configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2007,2008 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.446 2008/09/06 21:02:20 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.13.20020210)
  38 AC_REVISION($Revision: 1.446 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44
  45 CF_WITH_REL_VERSION(NCURSES)
  46 CF_WITH_ABI_VERSION
  47
  48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
  49 AC_ARG_WITH(system-type,
  50 [  --with-system-type=XXX  test: override derived host system-type],
  51 [AC_MSG_WARN(overriding system type to $withval)
  52  cf_cv_system_name=$withval])
  53
  54 ###     Save the given $CFLAGS to allow user-override.
  55 cf_user_CFLAGS="$CFLAGS"
  56
  57 ###     Default install-location
  58 CF_CFG_DEFAULTS
  59
  60 ###     Checks for programs.
  61 AC_PROG_CC
  62 CF_GCC_VERSION
  63
  64 AC_PROG_CPP
  65 AC_PROG_GCC_TRADITIONAL
  66 CF_PROG_CC_C_O(CC)
  67 AC_ISC_POSIX
  68 CF_ANSI_CC_REQD
  69 CF_PROG_EXT
  70 CF_PROG_LDCONFIG
  71
  72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  73 dnl                             configure script by not letting us test if C++
  74 dnl                             is present, making this option necessary.
  75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  76 AC_ARG_WITH(cxx,
  77         [  --without-cxx           do not adjust ncurses bool to match C++],
  78         [cf_with_cxx=$withval],
  79         [cf_with_cxx=yes])
  80 AC_MSG_RESULT($cf_with_cxx)
  81 if test "X$cf_with_cxx" = Xno ; then
  82         CXX=""
  83         GXX=""
  84 else
  85         # with autoconf 2.13, we can change the error to a warning:
  86         pushdef([AC_MSG_ERROR],
  87                 [AC_MSG_RESULT(no)
  88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  90         AC_PROG_CXX
  91         popdef([AC_MSG_ERROR])dnl
  92         # autoconf 2.5x removed the error - by hardcoding it to g++.
  93         if test "$CXX" = "g++" ; then
  94                 AC_PATH_PROG(CXX,g++)
  95         fi
  96         if test "$CXX" = "g++" ; then
  97                 AC_MSG_WARN(ignoring hardcoded g++)
  98                 cf_with_cxx=no; CXX=""; GXX="";
  99         fi
 100 fi
 101
 102 CF_GXX_VERSION
 103 case $GXX_VERSION in
 104 1*|2.[[0-6]]*)
 105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 106         # cf_cxx_library=no
 107         AC_MSG_WARN(templates do not work)
 108         ;;
 109 esac
 110
 111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 112 AC_ARG_WITH(cxx-binding,
 113         [  --without-cxx-binding   do not build C++ binding and demo],
 114         [cf_with_cxx_binding=$withval],
 115         [cf_with_cxx_binding=$cf_with_cxx])
 116 AC_MSG_RESULT($cf_with_cxx_binding)
 117
 118 AC_MSG_CHECKING(if you want to build with Ada95)
 119 AC_ARG_WITH(ada,
 120         [  --without-ada           suppress check for Ada95, don't build demo],
 121         [cf_with_ada=$withval],
 122         [cf_with_ada=yes])
 123 AC_MSG_RESULT($cf_with_ada)
 124
 125 AC_MSG_CHECKING(if you want to build programs such as tic)
 126 AC_ARG_WITH(progs,
 127         [  --without-progs         suppress build with programs (e.g., tic)],
 128         [cf_with_progs=$withval],
 129         [cf_with_progs=yes])
 130 AC_MSG_RESULT($cf_with_progs)
 131
 132 AC_MSG_CHECKING(if you wish to install curses.h)
 133 AC_ARG_WITH(curses-h,
 134         [  --without-curses-h      install curses.h as ncurses.h only],
 135         [with_curses_h=$withval],
 136         [with_curses_h=yes])
 137 AC_MSG_RESULT($with_curses_h)
 138
 139 modules_to_build="ncurses"
 140 if test "X$cf_with_progs" != Xno ; then
 141 modules_to_build="$modules_to_build progs tack"
 142 fi
 143 modules_to_build="$modules_to_build panel menu form"
 144
 145 AC_ARG_PROGRAM
 146
 147 CF_PROG_AWK
 148 CF_PROG_EGREP
 149 CF_PROG_INSTALL
 150 CF_PROG_LINT
 151 AC_PROG_LN_S
 152
 153 AC_SYS_LONG_FILE_NAMES
 154
 155 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 156 AC_ARG_ENABLE(mixed-case,
 157         [  --enable-mixed-case     tic should assume mixed-case filenames],
 158         [enable_mixedcase=$enableval],
 159         [enable_mixedcase=auto])
 160 AC_MSG_RESULT($enable_mixedcase)
 161 if test "$enable_mixedcase" = "auto" ; then
 162     CF_MIXEDCASE_FILENAMES
 163 else
 164     cf_cv_mixedcase=$enable_mixedcase
 165     if test "$enable_mixedcase" = "yes" ; then
 166         AC_DEFINE(MIXEDCASE_FILENAMES)
 167     fi
 168 fi
 169
 170 # do this after mixed-case option (tags/TAGS is not as important as tic).
 171 AC_PROG_MAKE_SET
 172 CF_MAKE_TAGS
 173 CF_MAKEFLAGS
 174
 175 dnl These are standard among *NIX systems, but not when cross-compiling
 176 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 177 AC_CHECK_TOOL(LD, ld, ld)
 178 AC_CHECK_TOOL(AR, ar, ar)
 179 CF_SUBST(archiver options,AR_OPTS,rv)
 180
 181 dnl Special option for use by system-builders: the install-prefix is used to
 182 dnl adjust the location into which the actual install is done, so that an
 183 dnl archive can be built without modifying the host system's configuration.
 184 AC_MSG_CHECKING(if you have specified an install-prefix)
 185 AC_ARG_WITH(install-prefix,
 186         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 187         [case "$withval" in #(vi
 188         yes|no) #(vi
 189                 ;;
 190         *)      DESTDIR="$withval"
 191                 ;;
 192         esac])
 193 AC_MSG_RESULT($DESTDIR)
 194 AC_SUBST(DESTDIR)
 195
 196 ###############################################################################
 197 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 198 # If we're cross-compiling, allow the user to override the tools and their
 199 # options.  The configure script is oriented toward identifying the host
 200 # compiler, etc., but we need a build compiler to generate parts of the source.
 201 CF_BUILD_CC
 202
 203 ###############################################################################
 204 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 205
 206 ### Options to allow the user to specify the set of libraries which are used.
 207 ### Use "--without-normal --with-shared" to allow the default model to be
 208 ### shared, for example.
 209 cf_list_models=""
 210 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 211
 212 CF_WITH_LIBTOOL
 213 if test "$with_libtool" != "no" ; then
 214
 215 cf_list_models="$cf_list_models libtool"
 216
 217 else
 218
 219 AC_MSG_CHECKING(if you want to build shared libraries)
 220 AC_ARG_WITH(shared,
 221         [  --with-shared           generate shared-libraries],
 222         [with_shared=$withval],
 223         [with_shared=no])
 224 AC_MSG_RESULT($with_shared)
 225 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
 226
 227 AC_MSG_CHECKING(if you want to build static libraries)
 228 AC_ARG_WITH(normal,
 229         [  --with-normal           generate normal-libraries (default)],
 230         [with_normal=$withval],
 231         [with_normal=yes])
 232 AC_MSG_RESULT($with_normal)
 233 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
 234
 235 AC_MSG_CHECKING(if you want to build debug libraries)
 236 AC_ARG_WITH(debug,
 237         [  --with-debug            generate debug-libraries (default)],
 238         [with_debug=$withval],
 239         [with_debug=yes])
 240 AC_MSG_RESULT($with_debug)
 241 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
 242
 243 AC_MSG_CHECKING(if you want to build profiling libraries)
 244 AC_ARG_WITH(profile,
 245         [  --with-profile          generate profile-libraries],
 246         [with_profile=$withval],
 247         [with_profile=no])
 248 AC_MSG_RESULT($with_profile)
 249 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
 250
 251 fi
 252
 253 ###############################################################################
 254
 255 AC_MSG_CHECKING(for specified models)
 256 test -z "$cf_list_models" && cf_list_models=normal
 257 dnl If we use libtool to generate libraries, then it must be the only
 258 dnl specified model.
 259 test "$with_libtool" != "no" && cf_list_models=libtool
 260 AC_MSG_RESULT($cf_list_models)
 261
 262 ### Use the first model as the default, and save its suffix for use in building
 263 ### up test-applications.
 264 AC_MSG_CHECKING(for default model)
 265 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 266 AC_MSG_RESULT($DFT_LWR_MODEL)
 267
 268 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 269
 270 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 271 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 272
 273 TICS_NAME=tic
 274 AC_SUBST(TICS_NAME)
 275
 276 TINFO_NAME=tinfo
 277 AC_SUBST(TINFO_NAME)
 278
 279 LIB_NAME=ncurses
 280 AC_SUBST(LIB_NAME)
 281
 282 LIB_DIR=../lib
 283 LIB_2ND=../../lib
 284
 285 CF_LIB_PREFIX(cf_prefix)
 286 LIB_PREFIX=$cf_prefix
 287 AC_SUBST(LIB_PREFIX)
 288
 289 LIB_SUFFIX=
 290 AC_SUBST(LIB_SUFFIX)
 291
 292 ###############################################################################
 293
 294 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 295 AC_ARG_WITH(termlib,
 296         [  --with-termlib          generate separate terminfo library],
 297         [with_termlib=$withval],
 298         [with_termlib=no])
 299 AC_MSG_RESULT($with_termlib)
 300
 301 AC_MSG_CHECKING(if you want to build a separate tic library)
 302 AC_ARG_WITH(ticlib,
 303         [  --with-ticlib           generate separate tic library],
 304         [with_ticlib=$withval],
 305         [with_ticlib=no])
 306 AC_MSG_RESULT($with_ticlib)
 307
 308 ### Checks for special libraries, must be done up-front.
 309 SHLIB_LIST=""
 310 CF_WITH_GPM
 311 if test "$with_gpm" != no ; then
 312         AC_MSG_CHECKING(if you want to load GPM dynamically)
 313         AC_ARG_WITH(dlsym,
 314                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 315                 [with_dlsym=$withval],
 316                 [with_dlsym=yes])
 317         AC_MSG_RESULT($with_dlsym)
 318         if test "$with_dlsym" = yes ; then
 319                 CF_FUNC_DLSYM
 320                 if test "$with_gpm" != yes ; then
 321                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 322                         cf_cv_gpm_soname="$with_gpm"
 323                 else
 324                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 325                 fi
 326                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
 327                 SHLIB_LIST="-ldl $SHLIB_LIST"
 328         else
 329                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 330         fi
 331         AC_DEFINE(HAVE_LIBGPM)
 332         CF_CHECK_GPM_WGETCH
 333 fi
 334
 335 CF_WITH_SYSMOUSE
 336
 337 dnl Not all ports of gcc support the -g option
 338
 339 if test X"$CC_G_OPT" = X"" ; then
 340         CC_G_OPT='-g'
 341         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
 342 fi
 343 AC_SUBST(CC_G_OPT)
 344
 345 if test X"$CXX_G_OPT" = X"" ; then
 346         CXX_G_OPT='-g'
 347         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
 348 fi
 349 AC_SUBST(CXX_G_OPT)
 350
 351 AC_MSG_CHECKING(for default loader flags)
 352 case $DFT_LWR_MODEL in
 353 libtool) LD_MODEL=''   ;;
 354 normal)  LD_MODEL=''   ;;
 355 debug)   LD_MODEL=$CC_G_OPT ;;
 356 profile) LD_MODEL='-pg';;
 357 shared)  LD_MODEL=''   ;;
 358 esac
 359 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 360 AC_MSG_RESULT($LD_MODEL)
 361
 362 case $DFT_LWR_MODEL in
 363 shared)
 364 AC_MSG_CHECKING(if rpath option should be used)
 365 AC_ARG_ENABLE(rpath,
 366 [  --enable-rpath          use rpath option when generating shared libraries],
 367 [cf_cv_ld_rpath=$enableval],
 368 [cf_cv_ld_rpath=no])
 369 AC_MSG_RESULT($cf_cv_ld_rpath)
 370 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 371 AC_ARG_ENABLE(relink,
 372 [  --disable-relink        relink shared libraries during install],
 373 [cf_cv_do_relink=$enableval],
 374 [cf_cv_do_relink=yes])
 375 AC_MSG_RESULT($cf_cv_do_relink)
 376         ;;
 377 esac
 378
 379 CF_SHARED_OPTS
 380 if test "$CC_SHARED_OPTS" = "unknown"; then
 381         for model in $cf_list_models; do
 382                 if test "$model" = "shared"; then
 383                         AC_ERROR(Shared libraries are not supported in this version)
 384                 fi
 385         done
 386 fi
 387
 388 ###############################################################################
 389 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 390
 391 ###     use option --disable-overwrite to leave out the link to -lcurses
 392 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 393 AC_ARG_ENABLE(overwrite,
 394         [  --disable-overwrite     leave out the link to -lcurses],
 395         [with_overwrite=$enableval],
 396         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 397 AC_MSG_RESULT($with_overwrite)
 398
 399 AC_MSG_CHECKING(if external terminfo-database is used)
 400 AC_ARG_ENABLE(database,
 401         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 402         [use_database=$enableval],
 403         [use_database=yes])
 404 AC_MSG_RESULT($use_database)
 405
 406 case $host_os in #(vi
 407 os2*) #(vi
 408         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 409         ;;
 410 *) #(vi
 411         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 412         ;;
 413 esac
 414 AC_SUBST(TERMINFO_SRC)
 415
 416 CF_PATHSEP
 417 if test "$use_database" != no ; then
 418         AC_DEFINE(USE_DATABASE)
 419
 420         AC_MSG_CHECKING(which terminfo source-file will be installed)
 421         AC_ARG_ENABLE(database,
 422                 [  --with-database=XXX     specify terminfo source to install],
 423                 [TERMINFO_SRC=$withval])
 424         AC_MSG_RESULT($TERMINFO_SRC)
 425
 426         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 427         AC_ARG_WITH(hashed-db,
 428                 [  --with-hashed-db        specify hashed-database library],,
 429                 [with_hashed_db=no])
 430         AC_MSG_RESULT($with_hashed_db)
 431 fi
 432
 433 AC_MSG_CHECKING(for list of fallback descriptions)
 434 AC_ARG_WITH(fallbacks,
 435         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 436         [with_fallback=$withval],
 437         [with_fallback=])
 438 AC_MSG_RESULT($with_fallback)
 439 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 440 AC_SUBST(FALLBACK_LIST)
 441
 442 AC_MSG_CHECKING(if you want modern xterm or antique)
 443 AC_ARG_WITH(xterm-new,
 444         [  --without-xterm-new     specify if xterm terminfo should be old version],
 445         [with_xterm_new=$withval],
 446         [with_xterm_new=yes])
 447 case $with_xterm_new in
 448 no)     with_xterm_new=xterm-old;;
 449 *)      with_xterm_new=xterm-new;;
 450 esac
 451 AC_MSG_RESULT($with_xterm_new)
 452 WHICH_XTERM=$with_xterm_new
 453 AC_SUBST(WHICH_XTERM)
 454
 455 MAKE_TERMINFO=
 456 if test "$use_database" = no ; then
 457         TERMINFO="${datadir}/terminfo"
 458         MAKE_TERMINFO="#"
 459 else
 460
 461 AC_MSG_CHECKING(for list of terminfo directories)
 462 CF_WITH_PATHLIST(terminfo-dirs,
 463         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 464         TERMINFO_DIRS,
 465         DATADIR/terminfo,
 466         ${datadir}/terminfo)
 467 AC_MSG_RESULT($TERMINFO_DIRS)
 468 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
 469
 470 AC_MSG_CHECKING(for default terminfo directory)
 471 CF_WITH_PATH(default-terminfo-dir,
 472         [  --with-default-terminfo-dir=DIR default terminfo directory],
 473         TERMINFO,
 474         DATADIR/terminfo,
 475         ${datadir}/terminfo)
 476 AC_MSG_RESULT($TERMINFO)
 477 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
 478
 479 fi
 480
 481 AC_SUBST(TERMINFO)
 482 AC_SUBST(MAKE_TERMINFO)
 483
 484 ###     use option --disable-big-core to make tic run on small machines
 485 ###     We need 4Mb, check if we can allocate 50% more than that.
 486 AC_MSG_CHECKING(if big-core option selected)
 487 AC_ARG_ENABLE(big-core,
 488         [  --disable-big-core      assume machine has little memory],
 489         [with_big_core=$enableval],
 490         [AC_TRY_RUN([
 491 #include <stdlib.h>
 492 #include <string.h>
 493 int main() {
 494         unsigned long n = 6000000L;
 495         char *s = malloc(n);
 496         if (s != 0)
 497                 s[0] = s[n-1] = 0;
 498         ${cf_cv_main_return:-return}(s == 0);
 499 }],
 500         [with_big_core=yes],
 501         [with_big_core=no],
 502         [with_big_core=no])])
 503 AC_MSG_RESULT($with_big_core)
 504 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
 505
 506 ### ISO C only guarantees 512-char strings, we have tables which load faster
 507 ### when constructed using "big" strings.  More than the C compiler, the awk
 508 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 509 AC_MSG_CHECKING(if big-strings option selected)
 510 AC_ARG_ENABLE(big-strings,
 511         [  --disable-big-strings   assume compiler has only standard-size strings],
 512         [with_big_strings=$enableval],
 513         [CF_AWK_BIG_PRINTF(4000,with_big_strings)])
 514 AC_MSG_RESULT($with_big_strings)
 515
 516 USE_BIG_STRINGS=0
 517 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
 518 AC_SUBST(USE_BIG_STRINGS)
 519
 520 ###     use option --enable-termcap to compile in the termcap fallback support
 521 AC_MSG_CHECKING(if you want termcap-fallback support)
 522 AC_ARG_ENABLE(termcap,
 523         [  --enable-termcap        compile in termcap fallback support],
 524         [with_termcap=$enableval],
 525         [with_termcap=no])
 526 AC_MSG_RESULT($with_termcap)
 527
 528 if test "$with_termcap" != "yes" ; then
 529         if test "$use_database" = no ; then
 530                 if test -z "$with_fallback" ; then
 531                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 532                 fi
 533         fi
 534         AC_DEFINE(PURE_TERMINFO)
 535 else
 536
 537 if test "$with_ticlib" != no ; then
 538         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 539 fi
 540
 541 AC_DEFINE(USE_TERMCAP)
 542 AC_MSG_CHECKING(for list of termcap files)
 543 CF_WITH_PATHLIST(termpath,
 544         [  --with-termpath=XXX     specify list of termcap files],
 545         TERMPATH,
 546         /etc/termcap:/usr/share/misc/termcap)
 547 AC_MSG_RESULT($TERMPATH)
 548 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
 549
 550 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 551 AC_MSG_CHECKING(if fast termcap-loader is needed)
 552 AC_ARG_ENABLE(getcap,
 553         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 554         [with_getcap=$enableval],
 555         [with_getcap=no])
 556 AC_MSG_RESULT($with_getcap)
 557 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
 558
 559 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 560 AC_ARG_ENABLE(getcap-cache,
 561         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 562         [with_getcap_cache=$enableval],
 563         [with_getcap_cache=no])
 564 AC_MSG_RESULT($with_getcap_cache)
 565 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
 566
 567 fi
 568
 569 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 570 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 571 AC_ARG_ENABLE(home-terminfo,
 572         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 573         [with_home_terminfo=$enableval],
 574         [with_home_terminfo=yes])
 575 AC_MSG_RESULT($with_home_terminfo)
 576 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
 577
 578 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 579 AC_ARG_ENABLE(root-environ,
 580         [  --disable-root-environ  restrict environment when running as root],
 581         [with_root_environ=$enableval],
 582         [with_root_environ=yes])
 583 AC_MSG_RESULT($with_root_environ)
 584 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
 585
 586 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 587 ###   to reduce storage requirements for the terminfo database.
 588 CF_LINK_FUNCS
 589
 590 with_links=no
 591 with_symlinks=no
 592
 593 # soft links (symbolic links) are useful for some systems where hard links do
 594 # not work, or to make it simpler to copy terminfo trees around.
 595 if test "$ac_cv_func_symlink" = yes ; then
 596     AC_MSG_CHECKING(if tic should use symbolic links)
 597     AC_ARG_ENABLE(symlinks,
 598         [  --enable-symlinks       make tic use symbolic links not hard links],
 599         [with_symlinks=$enableval],
 600         [with_symlinks=no])
 601     AC_MSG_RESULT($with_symlinks)
 602 fi
 603
 604 # If we have hard links and did not choose to use soft links instead, there is
 605 # no reason to make this choice optional - use the hard links.
 606 if test "$with_symlinks" = no ; then
 607     AC_MSG_CHECKING(if tic should use hard links)
 608     if test "$ac_cv_func_link" = yes ; then
 609         with_links=yes
 610     else
 611         with_links=no
 612     fi
 613     AC_MSG_RESULT($with_links)
 614 fi
 615
 616 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
 617 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
 618
 619 ###   use option --enable-broken-linker to force on use of broken-linker support
 620 AC_MSG_CHECKING(if you want broken-linker support code)
 621 AC_ARG_ENABLE(broken_linker,
 622         [  --enable-broken_linker  compile with broken-linker support code],
 623         [with_broken_linker=$enableval],
 624         [with_broken_linker=${BROKEN_LINKER-no}])
 625 AC_MSG_RESULT($with_broken_linker)
 626
 627 BROKEN_LINKER=0
 628 if test "$with_broken_linker" = yes ; then
 629         AC_DEFINE(BROKEN_LINKER)
 630         BROKEN_LINKER=1
 631 elif test "$DFT_LWR_MODEL" = shared ; then
 632         case $cf_cv_system_name in #(vi
 633         cygwin*)
 634                 AC_DEFINE(BROKEN_LINKER)
 635                 BROKEN_LINKER=1
 636                 CF_VERBOSE(cygwin linker is broken anyway)
 637                 ;;
 638         esac
 639 fi
 640 AC_SUBST(BROKEN_LINKER)
 641
 642 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 643 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 644 AC_ARG_ENABLE(bsdpad,
 645         [  --enable-bsdpad         recognize BSD-style prefix padding],
 646         [with_bsdpad=$enableval],
 647         [with_bsdpad=no])
 648 AC_MSG_RESULT($with_bsdpad)
 649 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
 650
 651 ###   use option --enable-widec to turn on use of wide-character support
 652 NCURSES_CH_T=chtype
 653 NCURSES_LIBUTF8=0
 654
 655 NEED_WCHAR_H=0
 656 NCURSES_MBSTATE_T=0
 657 NCURSES_WCHAR_T=0
 658 NCURSES_WINT_T=0
 659
 660 # Check to define _XOPEN_SOURCE "automatically"
 661 CF_XOPEN_SOURCE
 662
 663 # Work around breakage on OS X
 664 CF_SIGWINCH
 665
 666 # Checks for CODESET support.
 667 AM_LANGINFO_CODESET
 668
 669 # use these variables to work around a defect in gcc's fixincludes.
 670 NCURSES_OK_WCHAR_T=
 671 NCURSES_OK_WINT_T=
 672
 673 AC_MSG_CHECKING(if you want wide-character code)
 674 AC_ARG_ENABLE(widec,
 675         [  --enable-widec          compile with wide-char/UTF-8 code],
 676         [with_widec=$enableval],
 677         [with_widec=no])
 678 AC_MSG_RESULT($with_widec)
 679 if test "$with_widec" = yes ; then
 680         LIB_SUFFIX="w${LIB_SUFFIX}"
 681         AC_DEFINE(USE_WIDEC_SUPPORT)
 682         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 683         # with_overwrite=no
 684         NCURSES_CH_T=cchar_t
 685         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 686         if test "$ac_cv_func_putwc" != yes ; then
 687                 CF_LIBUTF8
 688                 if test "$cf_cv_libutf8" = yes ; then
 689                         NCURSES_LIBUTF8=1
 690                 fi
 691         fi
 692         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 693         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 694         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 695
 696         if test "$NCURSES_MBSTATE_T" != 0; then
 697                 AC_DEFINE(NEED_MBSTATE_T_DEF)
 698         fi
 699 fi
 700 AC_SUBST(NCURSES_CH_T)
 701 AC_SUBST(NCURSES_LIBUTF8)
 702
 703 AC_SUBST(NEED_WCHAR_H)
 704 AC_SUBST(NCURSES_MBSTATE_T)
 705 AC_SUBST(NCURSES_WCHAR_T)
 706 AC_SUBST(NCURSES_WINT_T)
 707
 708 AC_SUBST(NCURSES_OK_WCHAR_T)
 709 AC_SUBST(NCURSES_OK_WINT_T)
 710
 711 ###   use option --disable-lp64 to allow long chtype
 712 case $cf_cv_abi_version in
 713 [[345]]*)
 714         default_with_lp64=no
 715         ;;
 716 *)
 717         default_with_lp64=yes
 718         ;;
 719 esac
 720
 721 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 722 AC_ARG_ENABLE(lp64,
 723         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 724         [with_lp64=$enableval],
 725         [with_lp64=$default_with_lp64])
 726 AC_MSG_RESULT($with_lp64)
 727
 728 if test "$with_lp64" = yes ; then
 729         cf_cv_enable_lp64=1
 730 else
 731         cf_cv_enable_lp64=0
 732 fi
 733 AC_SUBST(cf_cv_enable_lp64)
 734
 735 CF_LARGEFILE
 736
 737 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 738 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 739 AC_ARG_ENABLE(tparm-varargs,
 740         [  --disable-tparm-varargs compile tparm() without varargs interface],
 741         [with_tparm_varargs=$enableval],
 742         [with_tparm_varargs=yes])
 743 AC_MSG_RESULT($with_tparm_varargs)
 744 NCURSES_TPARM_VARARGS=0
 745 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
 746 AC_SUBST(NCURSES_TPARM_VARARGS)
 747
 748 ###   use option --with-bool to override bool's type
 749 AC_MSG_CHECKING(for type of bool)
 750 AC_ARG_WITH(bool,
 751         [  --with-bool=TYPE        override fallback type of bool variable],
 752         [NCURSES_BOOL="$withval"],
 753         [NCURSES_BOOL=auto])
 754 AC_MSG_RESULT($NCURSES_BOOL)
 755 AC_SUBST(NCURSES_BOOL)
 756
 757 AC_MSG_CHECKING(for alternate terminal capabilities file)
 758 AC_ARG_WITH(caps,
 759         [  --with-caps=alt         compile with alternate Caps file],
 760         [TERMINFO_CAPS=Caps.$withval],
 761         [TERMINFO_CAPS=Caps])
 762 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 763 AC_MSG_RESULT($TERMINFO_CAPS)
 764 AC_SUBST(TERMINFO_CAPS)
 765
 766 ###   use option --with-chtype to override chtype's type
 767 AC_MSG_CHECKING(for type of chtype)
 768 AC_ARG_WITH(chtype,
 769         [  --with-chtype=TYPE      override type of chtype],
 770         [NCURSES_CHTYPE="$withval"],
 771         [NCURSES_CHTYPE=auto])
 772 AC_MSG_RESULT($NCURSES_CHTYPE)
 773
 774 ###   use option --with-ospeed to override ospeed's type
 775 AC_MSG_CHECKING(for type of ospeed)
 776 AC_ARG_WITH(ospeed,
 777         [  --with-ospeed=TYPE      override type of ospeed variable],
 778         [NCURSES_OSPEED="$withval"],
 779         [NCURSES_OSPEED=short])
 780 AC_MSG_RESULT($NCURSES_OSPEED)
 781 AC_SUBST(NCURSES_OSPEED)
 782
 783 ###   use option --with-mmask-t to override mmask_t's type
 784 AC_MSG_CHECKING(for type of mmask_t)
 785 AC_ARG_WITH(mmask-t,
 786         [  --with-mmask-t=TYPE     override type of mmask_t],
 787         [NCURSES_MMASK_T="$withval"],
 788         [NCURSES_MMASK_T=auto])
 789 AC_MSG_RESULT($NCURSES_MMASK_T)
 790
 791 ### Enable compiling-in rcs id's
 792 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
 793 AC_ARG_WITH(rcs-ids,
 794         [  --with-rcs-ids          compile-in RCS identifiers],
 795         [with_rcs_ids=$withval],
 796         [with_rcs_ids=no])
 797 AC_MSG_RESULT($with_rcs_ids)
 798 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
 799
 800 ###############################################################################
 801 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tic toe tput ])
 802
 803 ###############################################################################
 804 CF_HELP_MESSAGE(Extensions:)
 805
 806 ### Note that some functions (such as const) are normally disabled anyway.
 807 AC_MSG_CHECKING(if you want to build with function extensions)
 808 AC_ARG_ENABLE(ext-funcs,
 809         [  --disable-ext-funcs     disable function-extensions],
 810         [with_ext_funcs=$enableval],
 811         [with_ext_funcs=yes])
 812 AC_MSG_RESULT($with_ext_funcs)
 813 if test "$with_ext_funcs" = yes ; then
 814         NCURSES_EXT_FUNCS=1
 815         AC_DEFINE(HAVE_CURSES_VERSION)
 816         AC_DEFINE(HAVE_HAS_KEY)
 817         AC_DEFINE(HAVE_RESIZETERM)
 818         AC_DEFINE(HAVE_RESIZE_TERM)
 819         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
 820         AC_DEFINE(HAVE_WRESIZE)
 821         AC_DEFINE(NCURSES_EXT_FUNCS)
 822 else
 823         NCURSES_EXT_FUNCS=0
 824 fi
 825 AC_SUBST(NCURSES_EXT_FUNCS)
 826
 827 ###   use option --enable-const to turn on use of const beyond that in XSI.
 828 AC_MSG_CHECKING(for extended use of const keyword)
 829 AC_ARG_ENABLE(const,
 830         [  --enable-const          compile with extra/non-standard const],
 831         [with_ext_const=$enableval],
 832         [with_ext_const=no])
 833 AC_MSG_RESULT($with_ext_const)
 834 NCURSES_CONST='/*nothing*/'
 835 if test "$with_ext_const" = yes ; then
 836         NCURSES_CONST=const
 837 fi
 838 AC_SUBST(NCURSES_CONST)
 839
 840 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
 841 AC_MSG_CHECKING(if you want to use extended colors)
 842 AC_ARG_ENABLE(ext-colors,
 843         [  --enable-ext-colors     compile for 256-color support],
 844         [with_ext_colors=$enableval],
 845         [with_ext_colors=no])
 846 AC_MSG_RESULT($with_ext_colors)
 847 NCURSES_EXT_COLORS=0
 848 if test "$with_ext_colors" = yes ; then
 849         if test "$with_widec" != yes ; then
 850                 AC_MSG_ERROR(This option applies only to wide-character library)
 851         else
 852                 # cannot be ABI 5 since it changes sizeof(cchar_t)
 853                 CF_NCURSES_ABI_6
 854         fi
 855         NCURSES_EXT_COLORS=1
 856         AC_DEFINE(NCURSES_EXT_COLORS)
 857 fi
 858 AC_SUBST(NCURSES_EXT_COLORS)
 859
 860 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
 861 AC_MSG_CHECKING(if you want to use extended mouse encoding)
 862 AC_ARG_ENABLE(ext-mouse,
 863         [  --enable-ext-mouse      compile for extended mouse-encoding],
 864         [with_ext_mouse=$enableval],
 865         [with_ext_mouse=no])
 866 AC_MSG_RESULT($with_ext_mouse)
 867 NCURSES_MOUSE_VERSION=1
 868 if test "$with_ext_mouse" = yes ; then
 869         NCURSES_MOUSE_VERSION=2
 870         CF_NCURSES_ABI_6
 871 fi
 872 AC_SUBST(NCURSES_MOUSE_VERSION)
 873
 874 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
 875 AC_ARG_ENABLE(no-padding,
 876         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
 877         [with_no_padding=$enableval],
 878         [with_no_padding=$with_ext_funcs])
 879 AC_MSG_RESULT($with_no_padding)
 880 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
 881
 882 AC_CHECK_SIZEOF([signed char], 0)
 883 if test "$ac_cv_sizeof_signed_char" = 1 ; then
 884         NCURSES_SBOOL="signed char"
 885 else
 886         NCURSES_SBOOL="char"
 887 fi
 888 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
 889 AC_ARG_ENABLE(signed-char,
 890         [  --enable-signed-char    compile using signed Boolean's in term.h],
 891         [with_signed_char=$enableval],
 892         [with_signed_char=no])
 893 AC_MSG_RESULT($with_signed_char)
 894 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
 895 AC_SUBST(NCURSES_SBOOL)
 896
 897 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
 898 AC_MSG_CHECKING(if you want SIGWINCH handler)
 899 AC_ARG_ENABLE(sigwinch,
 900         [  --enable-sigwinch       compile with SIGWINCH handler],
 901         [with_sigwinch=$enableval],
 902         [with_sigwinch=$with_ext_funcs])
 903 AC_MSG_RESULT($with_sigwinch)
 904 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
 905
 906 ###   use option --enable-tcap-names to allow user to define new capabilities
 907 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
 908 AC_ARG_ENABLE(tcap-names,
 909         [  --enable-tcap-names     compile with user-definable terminal capabilities],
 910         [with_tcap_names=$enableval],
 911         [with_tcap_names=$with_ext_funcs])
 912 AC_MSG_RESULT($with_tcap_names)
 913 NCURSES_XNAMES=0
 914 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
 915 AC_SUBST(NCURSES_XNAMES)
 916
 917 ###############################################################################
 918 # These options are relatively safe to experiment with.
 919 CF_HELP_MESSAGE(Development Code:)
 920 AC_MSG_CHECKING(if you want all development code)
 921 AC_ARG_WITH(develop,
 922         [  --without-develop       disable development options],
 923         [with_develop=$withval],
 924         [with_develop=no])
 925 AC_MSG_RESULT($with_develop)
 926
 927 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
 928 AC_MSG_CHECKING(if you want hard-tabs code)
 929 AC_ARG_ENABLE(hard-tabs,
 930         [  --enable-hard-tabs      compile with hard-tabs code],,
 931         [enable_hard_tabs=$with_develop])
 932 AC_MSG_RESULT($enable_hard_tabs)
 933 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
 934
 935 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
 936 AC_MSG_CHECKING(if you want limited support for xmc)
 937 AC_ARG_ENABLE(xmc-glitch,
 938         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
 939         [enable_xmc_glitch=$with_develop])
 940 AC_MSG_RESULT($enable_xmc_glitch)
 941 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
 942
 943 ###############################################################################
 944 # These are just experimental, probably should not be in a package:
 945 CF_HELP_MESSAGE(Experimental Code:)
 946
 947 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
 948 AC_ARG_ENABLE(assumed-color,
 949         [  --disable-assumed-color do not assume anything about default-colors],
 950         [with_assumed_color=$enableval],
 951         [with_assumed_color=yes])
 952 AC_MSG_RESULT($with_assumed_color)
 953 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
 954
 955 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
 956 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
 957 AC_ARG_ENABLE(hashmap,
 958         [  --disable-hashmap       compile without hashmap scrolling-optimization],
 959         [with_hashmap=$enableval],
 960         [with_hashmap=yes])
 961 AC_MSG_RESULT($with_hashmap)
 962 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
 963
 964 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
 965 AC_MSG_CHECKING(if you want colorfgbg code)
 966 AC_ARG_ENABLE(colorfgbg,
 967         [  --enable-colorfgbg      compile with $COLORFGBG code],
 968         [with_colorfgbg=$enableval],
 969         [with_colorfgbg=no])
 970 AC_MSG_RESULT($with_colorfgbg)
 971 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
 972
 973 # This is still experimental (20080329), but should ultimately be moved to
 974 # the script-block --with-normal, etc.
 975 CF_WITH_PTHREAD
 976
 977 AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
 978 AC_ARG_ENABLE(weak-symbols,
 979     [  --enable-weak-symbols   enable weak-symbols for pthreads],
 980     [use_weak_symbols=$withval],
 981     [use_weak_symbols=no])
 982 AC_MSG_RESULT($use_weak_symbols)
 983 if test "$use_weak_symbols" = yes ; then
 984     CF_WEAK_SYMBOLS
 985 else
 986     cf_cv_weak_symbols=no
 987 fi
 988
 989 if test $cf_cv_weak_symbols = yes ; then
 990     AC_DEFINE(USE_WEAK_SYMBOLS)
 991 fi
 992
 993 PTHREAD=
 994 if test "$with_pthread" = "yes" ; then
 995     AC_DEFINE(USE_PTHREADS)
 996     enable_reentrant=yes
 997     if test $cf_cv_weak_symbols = yes ; then
 998         PTHREAD=-lpthread
 999     fi
1000 fi
1001 AC_SUBST(PTHREAD)
1002
1003 # Reentrant code has to be opaque; there's little advantage to making ncurses
1004 # opaque outside of that, so there is no --enable-opaque option.  We can use
1005 # this option without --with-pthreads, but this will be always set for
1006 # pthreads.
1007 AC_MSG_CHECKING(if you want experimental reentrant code)
1008 AC_ARG_ENABLE(reentrant,
1009         [  --enable-reentrant      compile with experimental reentrant code],
1010         [with_reentrant=$enableval],
1011         [with_reentrant=no])
1012 AC_MSG_RESULT($with_reentrant)
1013 if test "$with_reentrant" = yes ; then
1014         cf_cv_enable_reentrant=1
1015         cf_cv_enable_opaque="NCURSES_INTERNALS"
1016         NCURSES_OPAQUE=1
1017         NCURSES_SIZE_T=int
1018     if test $cf_cv_weak_symbols = yes ; then
1019         CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1020     else
1021         LIB_SUFFIX="t${LIB_SUFFIX}"
1022     fi
1023         AC_DEFINE(USE_REENTRANT)
1024         CF_NCURSES_ABI_6
1025 else
1026         cf_cv_enable_reentrant=0
1027         cf_cv_enable_opaque="NCURSES_OPAQUE"
1028         NCURSES_OPAQUE=0
1029         NCURSES_SIZE_T=short
1030 fi
1031 AC_SUBST(cf_cv_enable_reentrant)
1032 AC_SUBST(cf_cv_enable_opaque)
1033 AC_SUBST(NCURSES_OPAQUE)
1034 AC_SUBST(NCURSES_SIZE_T)
1035
1036 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1037 AC_ARG_ENABLE(safe-sprintf,
1038         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1039         [with_safe_sprintf=$enableval],
1040         [with_safe_sprintf=no])
1041 AC_MSG_RESULT($with_safe_sprintf)
1042 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1043
1044 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1045 # when hashmap is used scroll hints are useless
1046 if test "$with_hashmap" = no ; then
1047 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1048 AC_ARG_ENABLE(scroll-hints,
1049         [  --disable-scroll-hints  compile without scroll-hints code],
1050         [with_scroll_hints=$enableval],
1051         [with_scroll_hints=yes])
1052 AC_MSG_RESULT($with_scroll_hints)
1053 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1054 fi
1055
1056 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1057 AC_ARG_ENABLE(wgetch-events,
1058         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1059         [with_wgetch_events=$enableval],
1060         [with_wgetch_events=no])
1061 AC_MSG_RESULT($with_wgetch_events)
1062 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1063
1064 ###############################################################################
1065 CF_HELP_MESSAGE(Testing/development Options:)
1066
1067 ###     use option --disable-echo to suppress full display compiling commands
1068 AC_MSG_CHECKING(if you want to display full commands during build)
1069 AC_ARG_ENABLE(echo,
1070         [  --enable-echo           build: display "compiling" commands (default)],
1071         [with_echo=$enableval],
1072         [with_echo=yes])
1073 if test "$with_echo" = yes; then
1074         ECHO_LINK=
1075 else
1076         ECHO_LINK='@ echo linking $@ ... ;'
1077         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1078         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1079 fi
1080 AC_MSG_RESULT($with_echo)
1081 AC_SUBST(ECHO_LINK)
1082
1083 ###     use option --enable-warnings to turn on all gcc warnings
1084 AC_MSG_CHECKING(if you want to see compiler warnings)
1085 AC_ARG_ENABLE(warnings,
1086         [  --enable-warnings       build: turn on GCC compiler warnings],
1087         [with_warnings=$enableval])
1088 AC_MSG_RESULT($with_warnings)
1089
1090 if test "x$with_warnings" = "xyes"; then
1091         ADAFLAGS="$ADAFLAGS -gnatg"
1092         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1093         if test "$cf_with_cxx" = yes ; then
1094                 CF_GXX_WARNINGS(Wno-unused)
1095         fi
1096 fi
1097 CF_GCC_ATTRIBUTES
1098
1099 ###     use option --enable-assertions to turn on generation of assertion code
1100 AC_MSG_CHECKING(if you want to enable runtime assertions)
1101 AC_ARG_ENABLE(assertions,
1102         [  --enable-assertions     test: turn on generation of assertion code],
1103         [with_assertions=$enableval],
1104         [with_assertions=no])
1105 AC_MSG_RESULT($with_assertions)
1106 if test -n "$GCC"
1107 then
1108         if test "$with_assertions" = no
1109         then
1110                 AC_DEFINE(NDEBUG)
1111                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1112         else
1113                 ADAFLAGS="$ADAFLAGS -gnata"
1114         fi
1115 fi
1116
1117 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1118 CF_DISABLE_LEAKS
1119 AC_DEFINE(HAVE_NC_ALLOC_H)
1120
1121 ###     use option --enable-expanded to generate certain macros as functions
1122 AC_ARG_ENABLE(expanded,
1123         [  --enable-expanded       test: generate functions for certain macros],
1124         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1125
1126 ###     use option --disable-macros to suppress macros in favor of functions
1127 AC_ARG_ENABLE(macros,
1128         [  --disable-macros        test: use functions rather than macros],
1129         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1130
1131 # Normally we only add trace() to the debug-library.  Allow this to be
1132 # extended to all models of the ncurses library:
1133 cf_all_traces=no
1134 case "$CFLAGS $CPPFLAGS" in
1135 *-DTRACE*)
1136         cf_all_traces=yes
1137         ;;
1138 esac
1139
1140 AC_MSG_CHECKING(whether to add trace feature to all models)
1141 AC_ARG_WITH(trace,
1142 [  --with-trace            test: add trace() function to all models of ncurses],
1143 [cf_with_trace=$withval],
1144 [cf_with_trace=$cf_all_traces])
1145 AC_MSG_RESULT($cf_with_trace)
1146
1147 if test "$cf_with_trace" = yes ; then
1148         LIB_TRACING=all
1149         ADA_TRACE=TRUE
1150         CF_ADD_CFLAGS(-DTRACE)
1151 else
1152         LIB_TRACING=DEBUG
1153         ADA_TRACE=FALSE
1154 fi
1155
1156 AC_SUBST(ADA_TRACE)
1157
1158 ###     Checks for libraries.
1159 AC_CHECK_FUNC(gettimeofday,
1160         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1161
1162 AC_CHECK_LIB(bsd, gettimeofday,
1163         AC_DEFINE(HAVE_GETTIMEOFDAY)
1164         LIBS="$LIBS -lbsd")])dnl CLIX: bzero, select, gettimeofday
1165
1166 CF_MATH_LIB(MATH_LIB,sin(x))
1167 AC_SUBST(MATH_LIB)
1168
1169 ###     Checks for header files.
1170 AC_STDC_HEADERS
1171 AC_HEADER_DIRENT
1172 AC_HEADER_TIME
1173 CF_REGEX
1174
1175 dnl These are some other potentially nonportable headers.
1176 AC_CHECK_HEADERS( \
1177 fcntl.h \
1178 getopt.h \
1179 limits.h \
1180 locale.h \
1181 poll.h \
1182 sys/bsdtypes.h \
1183 sys/ioctl.h \
1184 sys/param.h \
1185 sys/poll.h \
1186 sys/select.h \
1187 sys/time.h \
1188 sys/times.h \
1189 ttyent.h \
1190 unistd.h \
1191 wctype.h \
1192 )
1193
1194 # check for ISC (this may also define _POSIX_SOURCE)
1195 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1196 if test "$ISC" = yes ; then
1197         AC_CHECK_LIB(cposix,main)
1198         AC_CHECK_LIB(inet,bzero,LIBS="$LIBS -linet")dnl also 'select()'
1199 fi
1200
1201 CF_SYS_TIME_SELECT
1202
1203 ###     checks for compiler characteristics
1204 AC_LANG_C
1205 AC_C_CONST
1206 CF_C_INLINE(NCURSES_INLINE,1200)
1207 CF_SIG_ATOMIC_T
1208
1209 if test $NCURSES_CHTYPE = auto ; then
1210         CF_TYPEOF_CHTYPE
1211 else
1212         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1213 fi
1214 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1215 AC_SUBST(cf_cv_typeof_chtype)
1216
1217 CF_UNSIGNED_LITERALS
1218 cf_cv_1UL="1"
1219 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1220 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1221 AC_SUBST(cf_cv_1UL)
1222
1223 if test $NCURSES_MMASK_T = auto ; then
1224         cf_cv_typeof_mmask_t=long
1225 else
1226         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1227 fi
1228 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1229 AC_SUBST(cf_cv_typeof_mmask_t)
1230
1231 ###     Checks for external-data
1232 CF_ERRNO
1233 CF_LINK_DATAONLY
1234
1235 ###     Checks for library functions.
1236 AC_CHECK_FUNCS( \
1237 getcwd \
1238 getegid \
1239 geteuid \
1240 getttynam \
1241 issetugid \
1242 poll \
1243 remove \
1244 select \
1245 setbuf \
1246 setbuffer \
1247 setvbuf \
1248 sigaction \
1249 sigvec \
1250 strdup \
1251 strstr \
1252 tcgetpgrp \
1253 times \
1254 vsnprintf \
1255 )
1256 if test "$with_getcap" = "yes" ; then
1257         CF_CGETENT
1258 fi
1259
1260 CF_ISASCII
1261 CF_STRUCT_SIGACTION
1262 CF_FUNC_NANOSLEEP
1263 CF_FUNC_TERMIOS
1264 CF_FUNC_VSSCANF
1265 CF_MKSTEMP
1266
1267 # setup for prototype of fallback for vsscanf()
1268 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1269
1270 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1271 if test "$cross_compiling" = yes ; then
1272         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1273 else
1274         AC_FUNC_SETVBUF_REVERSED
1275 fi
1276 AC_TYPE_SIGNAL
1277 CF_TYPE_SIGACTION
1278 CF_SIZECHANGE
1279 CF_FUNC_MEMMOVE
1280 CF_FUNC_POLL
1281
1282 # special check for test/ditto.c
1283 CF_FUNC_OPENPTY
1284 if test "$cf_cv_func_openpty" != no ; then
1285     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1286     AC_DEFINE(USE_XTERM_PTY)
1287     if test "$cf_cv_lib_util" = yes ; then
1288         TEST_LIBS="-lutil $TEST_LIBS"
1289     fi
1290 fi
1291 AC_SUBST(TEST_LIBS)
1292
1293 if test "$with_hashed_db" != no ; then
1294         AC_DEFINE(USE_HASHED_DB)
1295         CF_HASHED_DB($with_hashed_db)
1296 fi
1297
1298 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1299 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1300         CF_STRIP_G_OPT(CFLAGS)
1301         CF_STRIP_G_OPT(CXXFLAGS)
1302 fi
1303
1304 # Just in case, check if the C compiler has a bool type.
1305 CF_BOOL_DECL(cf_cv_cc_bool_type)
1306
1307 # Check for C++ compiler characteristics (and ensure that it's there!)
1308 if test -n "$CXX" ; then
1309         AC_LANG_CPLUSPLUS
1310         CF_STDCPP_LIBRARY
1311         CF_PROG_CC_C_O(CXX)
1312
1313         case $GXX_VERSION in
1314         1*|2.[0-6]*)
1315                 cf_cxx_library=yes
1316                 ;;
1317         *-2.7*|2.7*)
1318                 CF_GPP_LIBRARY
1319                 ;;
1320         *)
1321                 cf_cxx_library=no
1322                 ;;
1323         esac
1324
1325         AC_CHECK_HEADERS(iostream typeinfo)
1326
1327     if test x"$ac_cv_header_iostream" = xyes ; then
1328         AC_MSG_CHECKING(if iostream uses std-namespace)
1329         AC_TRY_COMPILE([
1330 #include <iostream>
1331 using std::endl;
1332 using std::cerr;],[
1333 cerr << "testing" << endl;
1334 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1335         AC_MSG_RESULT($cf_iostream_namespace)
1336         if test "$cf_iostream_namespace" = yes ; then
1337             AC_DEFINE(IOSTREAM_NAMESPACE)
1338         fi
1339     fi
1340
1341         CF_BOOL_DECL
1342         CF_BOOL_SIZE
1343         CF_ETIP_DEFINES
1344         CF_CPP_PARAM_INIT
1345         CF_CPP_STATIC_CAST
1346
1347         CXX_AR='$(AR)'
1348         CXX_AR_OPTS='$(AR_OPTS)'
1349         case $cf_cv_system_name in #(vi
1350         irix*) #(vi
1351             if test "$GXX" != yes ; then
1352                 CXX_AR='$(CXX)'
1353                 CXX_AR_OPTS='-ar -o'
1354             fi
1355             ;;
1356         sco3.2v5*) #(vi
1357             CXXLDFLAGS="-u main"
1358             ;;
1359         solaris2*)
1360             if test "$GXX" != yes ; then
1361                 CXX_AR='$(CXX)'
1362                 CXX_AR_OPTS='-xar -o'
1363             fi
1364             ;;
1365         esac
1366         AC_SUBST(CXXLDFLAGS)
1367         AC_SUBST(CXX_AR)
1368         AC_SUBST(CXX_AR_OPTS)
1369 else
1370         cf_cxx_library=no
1371         cf_cv_builtin_bool=1
1372
1373         # Just because we are not configuring against C++ right now does not
1374         # mean that a user will not want to use C++.  Some distributors disable
1375         # the C++ portion of this configuration as a shortcut (or just to avoid
1376         # compiling the demo in the c++ directory).  So we need a reasonable
1377         # default for the 'bool' type.
1378         #
1379         # Caveat: since the storage of the bool type is not standardized, it
1380         # may change.
1381
1382         if test "$NCURSES_BOOL" != auto ; then
1383                 cf_cv_type_of_bool=$NCURSES_BOOL
1384                 cf_cv_header_stdbool_h=0
1385         else
1386                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1387                         CF_BOOL_SIZE
1388                 else
1389                         AC_MSG_CHECKING(for fallback type of bool)
1390                         case "$host_cpu" in #(vi
1391                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1392                         *)      cf_cv_type_of_bool=int  ;;
1393                         esac
1394                         AC_MSG_RESULT($cf_cv_type_of_bool)
1395                 fi
1396         fi
1397 fi
1398 AC_SUBST(CXXLIBS)
1399
1400 # If the C compiler did not declare bool, and we did not determine that the C++
1401 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1402 # ncurses library use the same type as C++ bool.  Note that this allows one to
1403 # specify the type of bool in a configure-script option and postpone
1404 # integration with the C++ compiler provided that the types are compatible.
1405 USE_CXX_BOOL=1
1406 if test $cf_cv_cc_bool_type = 1
1407 then
1408         # oops: C has a bool.  Unlikely, but C++ could differ.
1409         USE_CXX_BOOL=0
1410 elif test $cf_cv_builtin_bool = 0
1411 then
1412         # C++ has no bool
1413         USE_CXX_BOOL=0
1414 else
1415         # this is the normal case
1416         USE_CXX_BOOL='defined(__cplusplus)'
1417 fi
1418 AC_SUBST(USE_CXX_BOOL)
1419
1420 CF_HELP_MESSAGE(Ada95 Binding Options:)
1421
1422 dnl If the Ada95 source-tree is present, add that to the build unless it will
1423 dnl not work, or was not requested.
1424 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1425
1426 dnl libtool does not know anything about GNAT, though a change made in 1998
1427 dnl provided for it "someday".  Disable the ada subtree if we are using
1428 dnl libtool -TD 20070714
1429 if test "$cf_with_ada" != "no" ; then
1430     if test "$with_libtool" != "no"; then
1431         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1432         cf_with_ada=no
1433     fi
1434 fi
1435
1436 dnl Check for availability of GNU Ada Translator (GNAT).
1437 dnl At the moment we support no other Ada95 compiler.
1438 if test "$cf_with_ada" != "no" ; then
1439 cf_ada_make=gnatmake
1440 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
1441 if test "$ac_cv_prog_gnat_exists" = no; then
1442    cf_ada_make=
1443 else
1444    CF_GNAT_VERSION
1445    AC_CHECK_PROG(M4_exists, m4, yes, no)
1446    if test "$ac_cv_prog_M4_exists" = no; then
1447       cf_cv_prog_gnat_correct=no
1448       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
1449    fi
1450    if test "$cf_cv_prog_gnat_correct" = yes; then
1451       AC_MSG_CHECKING(if GNAT works)
1452       CF_GNAT_TRY_RUN([procedure conftest;],
1453 [with Text_IO;
1454 with GNAT.OS_Lib;
1455 procedure conftest is
1456 begin
1457    Text_IO.Put ("Hello World");
1458    Text_IO.New_Line;
1459    GNAT.OS_Lib.OS_Exit (0);
1460 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
1461       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
1462    fi
1463 fi
1464 if test "$cf_cv_prog_gnat_correct" = yes; then
1465    ADAFLAGS="-O3 -gnatpn $ADAFLAGS"
1466
1467    AC_MSG_CHECKING(if GNAT pragma Unreferenced works)
1468    CF_GNAT_TRY_LINK([procedure conftest;],
1469 [with Text_IO;
1470 with GNAT.OS_Lib;
1471 procedure conftest is
1472    test : Integer;
1473    pragma Unreferenced (test);
1474 begin
1475    test := 1;
1476    Text_IO.Put ("Hello World");
1477    Text_IO.New_Line;
1478    GNAT.OS_Lib.OS_Exit (0);
1479 end conftest;],[cf_cv_pragma_unreferenced=yes],[cf_cv_pragma_unreferenced=no])
1480    AC_MSG_RESULT($cf_cv_pragma_unreferenced)
1481
1482    # if the pragma is supported, use it (needed in the Trace code).
1483    if test $cf_cv_pragma_unreferenced = yes ; then
1484       PRAGMA_UNREF=TRUE
1485    else
1486       PRAGMA_UNREF=FALSE
1487    fi
1488
1489    AC_ARG_WITH(ada-compiler,
1490         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
1491         [cf_ada_compiler=$withval],
1492         [cf_ada_compiler=gnatmake])
1493
1494    cf_ada_package=terminal_interface
1495
1496    AC_SUBST(cf_ada_make)
1497    AC_SUBST(cf_ada_compiler)
1498    AC_SUBST(cf_ada_package)
1499    AC_SUBST(ADAFLAGS)
1500    AC_SUBST(cf_compile_generics)
1501    AC_SUBST(cf_generic_objects)
1502    AC_SUBST(PRAGMA_UNREF)
1503
1504    CF_WITH_PATH(ada-include,
1505        [  --with-ada-include=DIR  Ada includes are in DIR],
1506        ADA_INCLUDE,
1507        PREFIX/lib/ada/adainclude,
1508        [$]prefix/lib/ada/adainclude)
1509    AC_SUBST(ADA_INCLUDE)
1510
1511    CF_WITH_PATH(ada-objects,
1512        [  --with-ada-objects=DIR  Ada objects are in DIR],
1513        ADA_OBJECTS,
1514        PREFIX/lib/ada/adalib,
1515        [$]prefix/lib/ada/adalib)
1516    AC_SUBST(ADA_OBJECTS)
1517
1518 fi
1519 fi
1520 else
1521    cf_with_ada=no
1522 fi
1523
1524 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1525 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1526 ###
1527 ### ticlib modules may be a separate library, otherwise contained in termlib.
1528 ### termlib modules may be a separate library, otherwise contained in ncurses.
1529 ###
1530 ### The of "+" or " " between the tokens controls the way the script
1531 ### chooses to split module lists into libraries.
1532 ###
1533 ### (see CF_LIB_RULES).
1534 AC_MSG_CHECKING(for library subsets)
1535 LIB_SUBSETS=
1536
1537 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1538         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1539         if test "$with_ticlib" != no ; then
1540                 LIB_SUBSETS="${LIB_SUBSETS} "
1541         else
1542                 LIB_SUBSETS="${LIB_SUBSETS}+"
1543         fi
1544 fi
1545
1546 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1547 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1548 if test "$with_termlib" != no ; then
1549         LIB_SUBSETS="${LIB_SUBSETS} "
1550 else
1551         LIB_SUBSETS="${LIB_SUBSETS}+"
1552 fi
1553
1554 LIB_SUBSETS="${LIB_SUBSETS}base"
1555 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1556 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1557
1558 AC_MSG_RESULT($LIB_SUBSETS)
1559
1560 ### Construct the list of include-directories to be generated
1561 CF_INCLUDE_DIRS
1562 CF_ADA_INCLUDE_DIRS
1563
1564 ### Build up pieces for makefile rules
1565 AC_MSG_CHECKING(default library suffix)
1566 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1567 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1568 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1569
1570 AC_MSG_CHECKING(default library-dependency suffix)
1571 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_DEP_SUFFIX)dnl
1572 DFT_LIB_SUFFIX=$DFT_DEP_SUFFIX
1573 if test $DFT_LWR_MODEL = shared ; then
1574         case $cf_cv_system_name in #(vi
1575         cygwin*)
1576                 DFT_DEP_SUFFIX=".dll.a"
1577                 DFT_LIB_SUFFIX=".dll"
1578                 ;;
1579         esac
1580 fi
1581 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1582 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1583
1584 AC_MSG_CHECKING(default object directory)
1585 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1586 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1587 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1588
1589 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1590 if test "$cf_with_cxx" = yes ; then
1591 AC_MSG_CHECKING(c++ library-dependency suffix)
1592 if test "$with_libtool" != "no"; then
1593         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1594 else
1595         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX)dnl we normally make a static library
1596 fi
1597 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1598 AC_SUBST(CXX_LIB_SUFFIX)
1599 fi
1600
1601 # do not want -ldl in build except as needed for -lncurses dependency
1602 if test "$with_dlsym" = yes ; then
1603 if test $DFT_LWR_MODEL = shared || \
1604    test $DFT_LWR_MODEL = libtool ; then
1605         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1606 fi
1607 fi
1608 ### Set up low-level terminfo dependencies for makefiles.
1609
1610 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1611 # do not need libdl
1612 TICS_LIST=
1613 if test "$with_dlsym" = yes ; then
1614         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1615 fi
1616
1617 if test "$with_ticlib" != no ; then
1618
1619         if test "$with_ticlib" != yes ; then
1620                 TICS_NAME=$with_ticlib
1621                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1622                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1623                 TICS_LIB_SUFFIX="${with_ticlib}"
1624         else
1625                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1626                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1627                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1628         fi
1629         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1630 else
1631         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1632 fi
1633 AC_SUBST(TICS_ARG_SUFFIX)
1634 AC_SUBST(TICS_DEP_SUFFIX)
1635 AC_SUBST(TICS_LIB_SUFFIX)
1636 AC_SUBST(TICS_ARGS)
1637
1638 if test "$with_termlib" != no ; then
1639
1640         if test "$with_termlib" != yes ; then
1641                 TINFO_NAME=$with_termlib
1642                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1643                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1644                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1645                 TINFO_LIB_SUFFIX="${with_termlib}"
1646         else
1647                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1648                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1649                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1650                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1651         fi
1652
1653         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1654         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1655         if test "$DFT_LWR_MODEL" = "libtool"; then
1656                 TEST_ARGS="${TEST_DEPS}"
1657                 TEST_ARG2="${TEST_DEP2}"
1658                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1659         else
1660                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1661                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1662                 TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1663                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1664                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1665         fi
1666 else
1667         # the next lines are needed for linking libtic over libncurses
1668         TINFO_NAME=${LIB_NAME}
1669         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1670         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1671         TICS_LIST="$SHLIB_LIST"
1672
1673         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1674 fi
1675
1676 if test "$DFT_LWR_MODEL" = shared ; then
1677         case $cf_cv_system_name in #(vi
1678         cygwin*)
1679                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1680                 TINFO_SUFFIX=.dll
1681                 ;;
1682         esac
1683 fi
1684
1685 AC_SUBST(TINFO_ARG_SUFFIX)
1686 AC_SUBST(TINFO_DEP_SUFFIX)
1687 AC_SUBST(TINFO_LIB_SUFFIX)
1688 AC_SUBST(TINFO_ARGS)
1689
1690 if test "$with_dlsym" = yes ; then
1691         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1692 fi
1693
1694 if test "$DFT_LWR_MODEL" = "libtool"; then
1695     OBJEXT=lo
1696 fi
1697
1698 # needed for Ada95
1699 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1700 AC_SUBST(TINFO_ARGS2)
1701
1702 case $DFT_LWR_MODEL in
1703 normal|debug|profile)
1704         CF_LDFLAGS_STATIC
1705         ;;
1706 esac
1707
1708 AC_MSG_CHECKING(where we will install curses.h)
1709 test "$with_overwrite" = no && \
1710 test "x$includedir" = 'x${prefix}/include' && \
1711         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1712 AC_MSG_RESULT($includedir)
1713
1714 ### Resolve a conflict between normal and wide-curses by forcing applications
1715 ### that will need libutf8 to add it to their configure script.
1716 if test "$with_overwrite" != no ; then
1717 if test "$NCURSES_LIBUTF8" = 1 ; then
1718         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1719         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1720 fi
1721 fi
1722
1723 AC_SUBST(WITH_OVERWRITE)
1724 AC_SUBST(TICS_LIST)
1725 AC_SUBST(TINFO_LIST)
1726 AC_SUBST(SHLIB_LIST)
1727
1728 # used to separate tack out of the tree
1729 NCURSES_TREE=
1730 AC_SUBST(NCURSES_TREE)
1731
1732 ### predefined stuff for the test programs
1733 AC_DEFINE(HAVE_SLK_COLOR)
1734
1735 ### Construct the list of subdirectories for which we'll customize makefiles
1736 ### with the appropriate compile-rules.
1737
1738 CF_SRC_MODULES($modules_to_build)
1739
1740 if test "$cf_with_ada" != "no" && test "$cf_cv_prog_gnat_correct" != "no"; then
1741    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses-config"
1742 fi
1743
1744 CF_DIRS_TO_MAKE
1745
1746 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATHSEP')
1747
1748 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1749
1750 ### Now that we're done running tests, add the compiler-warnings, if any
1751 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1752
1753 ### If we're building with rpath, try to link non-standard libs that way too.
1754 if test "$DFT_LWR_MODEL" = "shared"; then
1755   CF_RPATH_HACK
1756 fi
1757
1758 ### Define substitutions for header files to avoid name-pollution
1759 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1760 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1761 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1762
1763 ################################################################################
1764 test "$use_database" = yes && SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1765 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1766 AC_OUTPUT( \
1767         include/MKterm.h.awk \
1768         include/curses.head:include/curses.h.in \
1769         include/termcap.h \
1770         include/unctrl.h \
1771         $SUB_MAKEFILES \
1772         Makefile,[
1773 CF_PRG_RULES([$srcdir/test/mk-test.awk ECHO_LINK="$ECHO_LINK"], test)
1774 CF_LIB_RULES($SRC_SUBDIRS)
1775 ],[
1776 ### Special initialization commands, used to pass information from the
1777 ### configuration-run into config.status
1778
1779 AWK="$AWK"
1780 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1781 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1782 ECHO_LINK="$ECHO_LINK"
1783 LDCONFIG="$LDCONFIG"
1784 LIB_NAME="$LIB_NAME"
1785 LIB_SUBSETS="$LIB_SUBSETS"
1786 LIB_SUFFIX="$LIB_SUFFIX"
1787 LIB_TRACING="$LIB_TRACING"
1788 MAKE_TERMINFO="$MAKE_TERMINFO"
1789 NCURSES_MAJOR="$NCURSES_MAJOR"
1790 NCURSES_MINOR="$NCURSES_MINOR"
1791 NCURSES_OSPEED="$NCURSES_OSPEED"
1792 NCURSES_PATCH="$NCURSES_PATCH"
1793 SRC_SUBDIRS="$SRC_SUBDIRS"
1794 TERMINFO="$TERMINFO"
1795 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1796 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1797 TINFO_NAME="$TINFO_NAME"
1798 TINFO_SUFFIX="$TINFO_SUFFIX"
1799 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1800 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1801 TICS_NAME="$TICS_NAME"
1802 WITH_CURSES_H="$with_curses_h"
1803 WITH_ECHO="$with_echo"
1804 WITH_OVERWRITE="$with_overwrite"
1805 cf_LIST_MODELS="$cf_list_models"
1806 cf_cv_abi_version="$cf_cv_abi_version"
1807 cf_cv_do_relink="$cf_cv_do_relink"
1808 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1809 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1810 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1811 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1812 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1813 cf_cv_rel_version="$cf_cv_rel_version"
1814 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1815 cf_cv_shlib_version="$cf_cv_shlib_version"
1816 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1817 cf_cv_system_name="$cf_cv_system_name"
1818 cf_with_cxx_binding="$cf_with_cxx_binding"
1819 host="$host"
1820 target="$target"
1821
1822 ],cat)dnl
1823 ${MAKE-make} preinstall