configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2010,2011 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.520 2011/03/28 00:22:26 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.13.20020210)
  38 AC_REVISION($Revision: 1.520 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44
  45 CF_WITH_REL_VERSION(NCURSES)
  46 CF_WITH_ABI_VERSION
  47
  48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
  49 AC_ARG_WITH(system-type,
  50 [  --with-system-type=XXX  test: override derived host system-type],
  51 [AC_MSG_WARN(overriding system type to $withval)
  52  cf_cv_system_name=$withval])
  53
  54 ###     Save the given $CFLAGS to allow user-override.
  55 cf_user_CFLAGS="$CFLAGS"
  56
  57 ###     Default install-location
  58 CF_CFG_DEFAULTS
  59
  60 ###     Checks for programs.
  61 AC_PROG_CC
  62 CF_GCC_VERSION
  63
  64 AC_PROG_CPP
  65 AC_PROG_GCC_TRADITIONAL
  66 CF_PROG_CC_C_O(CC)
  67 AC_ISC_POSIX
  68 CF_ANSI_CC_REQD
  69 CF_PROG_EXT
  70 CF_PROG_LDCONFIG
  71
  72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  73 dnl                             configure script by not letting us test if C++
  74 dnl                             is present, making this option necessary.
  75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  76 AC_ARG_WITH(cxx,
  77         [  --without-cxx           do not adjust ncurses bool to match C++],
  78         [cf_with_cxx=$withval],
  79         [cf_with_cxx=yes])
  80 AC_MSG_RESULT($cf_with_cxx)
  81 if test "X$cf_with_cxx" = Xno ; then
  82         CXX=""
  83         GXX=""
  84 else
  85         # with autoconf 2.13, we can change the error to a warning:
  86         pushdef([AC_MSG_ERROR],
  87                 [AC_MSG_RESULT(no)
  88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  90         AC_PROG_CXX
  91         popdef([AC_MSG_ERROR])dnl
  92         # autoconf 2.5x removed the error - by hardcoding it to g++.
  93         if test "$CXX" = "g++" ; then
  94                 AC_PATH_PROG(CXX,g++)
  95         fi
  96         if test "$CXX" = "g++" ; then
  97                 AC_MSG_WARN(ignoring hardcoded g++)
  98                 cf_with_cxx=no; CXX=""; GXX="";
  99         fi
 100 fi
 101
 102 CF_GXX_VERSION
 103 case $GXX_VERSION in
 104 1*|2.[[0-6]]*)
 105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 106         # cf_cxx_library=no
 107         AC_MSG_WARN(templates do not work)
 108         ;;
 109 esac
 110
 111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 112 AC_ARG_WITH(cxx-binding,
 113         [  --without-cxx-binding   do not build C++ binding and demo],
 114         [cf_with_cxx_binding=$withval],
 115         [cf_with_cxx_binding=$cf_with_cxx])
 116 AC_MSG_RESULT($cf_with_cxx_binding)
 117
 118 AC_MSG_CHECKING(if you want to build with Ada95)
 119 AC_ARG_WITH(ada,
 120         [  --without-ada           suppress check for Ada95, don't build demo],
 121         [cf_with_ada=$withval],
 122         [cf_with_ada=yes])
 123 AC_MSG_RESULT($cf_with_ada)
 124
 125 AC_MSG_CHECKING(if you want to install manpages)
 126 AC_ARG_WITH(manpages,
 127         [  --without-manpages      suppress install of manpages],
 128         [cf_with_manpages=$withval],
 129         [cf_with_manpages=yes])
 130 AC_MSG_RESULT($cf_with_manpages)
 131
 132 AC_MSG_CHECKING(if you want to build programs such as tic)
 133 AC_ARG_WITH(progs,
 134         [  --without-progs         suppress build with programs (e.g., tic)],
 135         [cf_with_progs=$withval],
 136         [cf_with_progs=yes])
 137 AC_MSG_RESULT($cf_with_progs)
 138
 139 AC_MSG_CHECKING(if you want to build test-programs)
 140 AC_ARG_WITH(tests,
 141         [  --without-tests         suppress build with test-programs],
 142         [cf_with_tests=$withval],
 143         [cf_with_tests=yes])
 144 AC_MSG_RESULT($cf_with_tests)
 145
 146 AC_MSG_CHECKING(if you wish to install curses.h)
 147 AC_ARG_WITH(curses-h,
 148         [  --without-curses-h      install curses.h as ncurses.h only],
 149         [with_curses_h=$withval],
 150         [with_curses_h=yes])
 151 AC_MSG_RESULT($with_curses_h)
 152
 153 modules_to_build="ncurses"
 154 if test "X$cf_with_progs" != Xno ; then
 155 modules_to_build="$modules_to_build progs tack"
 156 fi
 157 modules_to_build="$modules_to_build panel menu form"
 158
 159 AC_ARG_PROGRAM
 160
 161 CF_PROG_AWK
 162 CF_PROG_EGREP
 163 CF_PROG_INSTALL
 164 CF_PROG_LINT
 165 CF_PROG_LN_S
 166
 167 AC_SYS_LONG_FILE_NAMES
 168
 169 # if we find pkg-config, check if we should install the ".pc" files.
 170 CF_PKG_CONFIG
 171
 172 if test "$PKG_CONFIG" != no ; then
 173         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
 174
 175         # Leave this as something that can be overridden in the environment.
 176         if test -z "$PKG_CONFIG_LIBDIR" ; then
 177                 PKG_CONFIG_LIBDIR=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`/lib/pkgconfig
 178         fi
 179         PKG_CONFIG_LIBDIR=`echo "$PKG_CONFIG_LIBDIR" | sed -e 's/^://' -e 's/:.*//'`
 180         if test -n "$PKG_CONFIG_LIBDIR" && test -d "$PKG_CONFIG_LIBDIR" ; then
 181                 AC_ARG_ENABLE(pc-files,
 182                         [  --enable-pc-files       generate and install .pc files for pkg-config],
 183                         [enable_pc_files=$enableval],
 184                         [enable_pc_files=no])
 185                 AC_MSG_RESULT($enable_pc_files)
 186         else
 187                 AC_MSG_RESULT(no)
 188                 AC_MSG_WARN(did not find library $PKG_CONFIG_LIBDIR)
 189                 enable_pc_files=no
 190         fi
 191 fi
 192 AC_SUBST(PKG_CONFIG_LIBDIR)
 193
 194 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 195 AC_ARG_ENABLE(mixed-case,
 196         [  --enable-mixed-case     tic should assume mixed-case filenames],
 197         [enable_mixedcase=$enableval],
 198         [enable_mixedcase=auto])
 199 AC_MSG_RESULT($enable_mixedcase)
 200 if test "$enable_mixedcase" = "auto" ; then
 201     CF_MIXEDCASE_FILENAMES
 202 else
 203     cf_cv_mixedcase=$enable_mixedcase
 204     if test "$enable_mixedcase" = "yes" ; then
 205         AC_DEFINE(MIXEDCASE_FILENAMES)
 206     fi
 207 fi
 208
 209 # do this after mixed-case option (tags/TAGS is not as important as tic).
 210 AC_PROG_MAKE_SET
 211 CF_MAKE_TAGS
 212 CF_MAKEFLAGS
 213
 214 dnl These are standard among *NIX systems, but not when cross-compiling
 215 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 216 AC_CHECK_TOOL(LD, ld, ld)
 217 AC_CHECK_TOOL(AR, ar, ar)
 218 CF_AR_FLAGS
 219
 220 dnl Special option for use by system-builders: the install-prefix is used to
 221 dnl adjust the location into which the actual install is done, so that an
 222 dnl archive can be built without modifying the host system's configuration.
 223 AC_MSG_CHECKING(if you have specified an install-prefix)
 224 AC_ARG_WITH(install-prefix,
 225         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 226         [case "$withval" in #(vi
 227         yes|no) #(vi
 228                 ;;
 229         *)      DESTDIR="$withval"
 230                 ;;
 231         esac])
 232 AC_MSG_RESULT($DESTDIR)
 233 AC_SUBST(DESTDIR)
 234
 235 ###############################################################################
 236 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 237 # If we're cross-compiling, allow the user to override the tools and their
 238 # options.  The configure script is oriented toward identifying the host
 239 # compiler, etc., but we need a build compiler to generate parts of the source.
 240 CF_BUILD_CC
 241
 242 ###############################################################################
 243 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 244
 245 ### Options to allow the user to specify the set of libraries which are used.
 246 ### Use "--without-normal --with-shared" to allow the default model to be
 247 ### shared, for example.
 248 cf_list_models=""
 249 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 250
 251 CF_WITH_LIBTOOL
 252 if test "$with_libtool" != "no" ; then
 253
 254 cf_list_models="$cf_list_models libtool"
 255
 256 else
 257
 258 AC_MSG_CHECKING(if you want to build shared libraries)
 259 AC_ARG_WITH(shared,
 260         [  --with-shared           generate shared-libraries],
 261         [with_shared=$withval],
 262         [with_shared=no])
 263 AC_MSG_RESULT($with_shared)
 264 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
 265
 266 AC_MSG_CHECKING(if you want to build static libraries)
 267 AC_ARG_WITH(normal,
 268         [  --with-normal           generate normal-libraries (default)],
 269         [with_normal=$withval],
 270         [with_normal=yes])
 271 AC_MSG_RESULT($with_normal)
 272 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
 273
 274 AC_MSG_CHECKING(if you want to build debug libraries)
 275 AC_ARG_WITH(debug,
 276         [  --with-debug            generate debug-libraries (default)],
 277         [with_debug=$withval],
 278         [with_debug=yes])
 279 AC_MSG_RESULT($with_debug)
 280 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
 281
 282 AC_MSG_CHECKING(if you want to build profiling libraries)
 283 AC_ARG_WITH(profile,
 284         [  --with-profile          generate profile-libraries],
 285         [with_profile=$withval],
 286         [with_profile=no])
 287 AC_MSG_RESULT($with_profile)
 288 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
 289
 290 fi
 291
 292 ###############################################################################
 293
 294 AC_MSG_CHECKING(for specified models)
 295 test -z "$cf_list_models" && cf_list_models=normal
 296 dnl If we use libtool to generate libraries, then it must be the only
 297 dnl specified model.
 298 test "$with_libtool" != "no" && cf_list_models=libtool
 299 AC_MSG_RESULT($cf_list_models)
 300
 301 ### Use the first model as the default, and save its suffix for use in building
 302 ### up test-applications.
 303 AC_MSG_CHECKING(for default model)
 304 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 305 AC_MSG_RESULT($DFT_LWR_MODEL)
 306
 307 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 308
 309 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 310 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 311
 312 TICS_NAME=tic
 313 AC_SUBST(TICS_NAME)
 314
 315 TINFO_NAME=tinfo
 316 AC_SUBST(TINFO_NAME)
 317
 318 LIB_NAME=ncurses
 319 AC_SUBST(LIB_NAME)
 320
 321 LIB_DIR=../lib
 322 LIB_2ND=../../lib
 323
 324 CF_LIB_PREFIX(cf_prefix)
 325 LIB_PREFIX=$cf_prefix
 326 AC_SUBST(LIB_PREFIX)
 327
 328 LIB_SUFFIX=
 329 AC_SUBST(LIB_SUFFIX)
 330
 331 ###############################################################################
 332
 333 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 334 AC_ARG_WITH(termlib,
 335         [  --with-termlib          generate separate terminfo library],
 336         [with_termlib=$withval],
 337         [with_termlib=no])
 338 AC_MSG_RESULT($with_termlib)
 339
 340 AC_MSG_CHECKING(if you want to build a separate tic library)
 341 AC_ARG_WITH(ticlib,
 342         [  --with-ticlib           generate separate tic library],
 343         [with_ticlib=$withval],
 344         [with_ticlib=no])
 345 AC_MSG_RESULT($with_ticlib)
 346
 347 ### Checks for special libraries, must be done up-front.
 348 SHLIB_LIST=""
 349 CF_WITH_GPM
 350 if test "$with_gpm" != no ; then
 351         AC_MSG_CHECKING(if you want to load GPM dynamically)
 352         AC_ARG_WITH(dlsym,
 353                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 354                 [with_dlsym=$withval],
 355                 [with_dlsym=yes])
 356         AC_MSG_RESULT($with_dlsym)
 357         if test "$with_dlsym" = yes ; then
 358                 CF_FUNC_DLSYM
 359                 if test "$with_gpm" != yes ; then
 360                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 361                         cf_cv_gpm_soname="$with_gpm"
 362                 else
 363                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 364                 fi
 365                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
 366                 SHLIB_LIST="-ldl $SHLIB_LIST"
 367         else
 368                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 369                 CF_ADD_LIB(gpm,TEST_LIBS)
 370         fi
 371         AC_DEFINE(HAVE_LIBGPM)
 372         CF_CHECK_GPM_WGETCH
 373 fi
 374
 375 CF_WITH_SYSMOUSE
 376
 377 dnl Not all ports of gcc support the -g option
 378
 379 if test X"$CC_G_OPT" = X"" ; then
 380         CC_G_OPT='-g'
 381         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
 382 fi
 383 AC_SUBST(CC_G_OPT)
 384
 385 if test X"$CXX_G_OPT" = X"" ; then
 386         CXX_G_OPT='-g'
 387         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
 388 fi
 389 AC_SUBST(CXX_G_OPT)
 390
 391 AC_MSG_CHECKING(for default loader flags)
 392 case $DFT_LWR_MODEL in
 393 libtool) LD_MODEL=''   ;;
 394 normal)  LD_MODEL=''   ;;
 395 debug)   LD_MODEL=$CC_G_OPT ;;
 396 profile) LD_MODEL='-pg';;
 397 shared)  LD_MODEL=''   ;;
 398 esac
 399 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 400 AC_MSG_RESULT($LD_MODEL)
 401
 402 case $DFT_LWR_MODEL in
 403 shared)
 404 CF_ENABLE_RPATH
 405 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 406 AC_ARG_ENABLE(relink,
 407 [  --disable-relink        relink shared libraries during install],
 408 [cf_cv_do_relink=$enableval],
 409 [cf_cv_do_relink=yes])
 410 AC_MSG_RESULT($cf_cv_do_relink)
 411         ;;
 412 esac
 413
 414 CF_SHARED_OPTS
 415 if test "$CC_SHARED_OPTS" = "unknown"; then
 416         for model in $cf_list_models; do
 417                 if test "$model" = "shared"; then
 418                         AC_ERROR(Shared libraries are not supported in this version)
 419                 fi
 420         done
 421 fi
 422
 423 ### If we're building with rpath, try to link non-standard libs that way too.
 424 if test "$DFT_LWR_MODEL" = "shared"; then
 425         CF_DISABLE_RPATH_HACK
 426 fi
 427
 428 ###############################################################################
 429 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 430
 431 ###     use option --disable-overwrite to leave out the link to -lcurses
 432 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 433 AC_ARG_ENABLE(overwrite,
 434         [  --disable-overwrite     leave out the link to -lcurses],
 435         [with_overwrite=$enableval],
 436         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 437 AC_MSG_RESULT($with_overwrite)
 438
 439 AC_MSG_CHECKING(if external terminfo-database is used)
 440 AC_ARG_ENABLE(database,
 441         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 442         [use_database=$enableval],
 443         [use_database=yes])
 444 AC_MSG_RESULT($use_database)
 445
 446 case $host_os in #(vi
 447 os2*) #(vi
 448         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 449         ;;
 450 *) #(vi
 451         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 452         ;;
 453 esac
 454 AC_SUBST(TERMINFO_SRC)
 455
 456 CF_PATHSEP
 457 if test "$use_database" != no ; then
 458         AC_DEFINE(USE_DATABASE)
 459
 460         AC_MSG_CHECKING(which terminfo source-file will be installed)
 461         AC_ARG_WITH(database,
 462                 [  --with-database=XXX     specify terminfo source to install],
 463                 [TERMINFO_SRC=$withval])
 464         AC_MSG_RESULT($TERMINFO_SRC)
 465
 466         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 467         AC_ARG_WITH(hashed-db,
 468                 [  --with-hashed-db        specify hashed-database library],,
 469                 [with_hashed_db=no])
 470         AC_MSG_RESULT($with_hashed_db)
 471 else
 472         with_hashed_db=no
 473 fi
 474
 475 AC_MSG_CHECKING(for list of fallback descriptions)
 476 AC_ARG_WITH(fallbacks,
 477         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 478         [with_fallback=$withval],
 479         [with_fallback=])
 480 AC_MSG_RESULT($with_fallback)
 481 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 482 AC_SUBST(FALLBACK_LIST)
 483
 484 AC_MSG_CHECKING(if you want modern xterm or antique)
 485 AC_ARG_WITH(xterm-new,
 486         [  --without-xterm-new     specify if xterm terminfo should be old version],
 487         [with_xterm_new=$withval],
 488         [with_xterm_new=yes])
 489 case $with_xterm_new in
 490 no)     with_xterm_new=xterm-old;;
 491 *)      with_xterm_new=xterm-new;;
 492 esac
 493 AC_MSG_RESULT($with_xterm_new)
 494 WHICH_XTERM=$with_xterm_new
 495 AC_SUBST(WHICH_XTERM)
 496
 497 MAKE_TERMINFO=
 498 if test "$use_database" = no ; then
 499         TERMINFO="${datadir}/terminfo"
 500         MAKE_TERMINFO="#"
 501 else
 502
 503 AC_MSG_CHECKING(for list of terminfo directories)
 504 CF_WITH_PATHLIST(terminfo-dirs,
 505         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 506         TERMINFO_DIRS,
 507         DATADIR/terminfo,
 508         ${datadir}/terminfo)
 509 AC_MSG_RESULT($TERMINFO_DIRS)
 510 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
 511
 512 AC_MSG_CHECKING(for default terminfo directory)
 513 CF_WITH_PATH(default-terminfo-dir,
 514         [  --with-default-terminfo-dir=DIR default terminfo directory],
 515         TERMINFO,
 516         DATADIR/terminfo,
 517         ${datadir}/terminfo)
 518 AC_MSG_RESULT($TERMINFO)
 519 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
 520
 521 fi
 522
 523 AC_SUBST(TERMINFO)
 524 AC_SUBST(MAKE_TERMINFO)
 525
 526 ###     use option --disable-big-core to make tic run on small machines
 527 ###     We need 4Mb, check if we can allocate 50% more than that.
 528 AC_MSG_CHECKING(if big-core option selected)
 529 AC_ARG_ENABLE(big-core,
 530         [  --disable-big-core      assume machine has little memory],
 531         [with_big_core=$enableval],
 532         [AC_TRY_RUN([
 533 #include <stdlib.h>
 534 #include <string.h>
 535 int main() {
 536         unsigned long n = 6000000L;
 537         char *s = malloc(n);
 538         if (s != 0)
 539                 s[0] = s[n-1] = 0;
 540         ${cf_cv_main_return:-return}(s == 0);
 541 }],
 542         [with_big_core=yes],
 543         [with_big_core=no],
 544         [with_big_core=no])])
 545 AC_MSG_RESULT($with_big_core)
 546 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
 547
 548 ### ISO C only guarantees 512-char strings, we have tables which load faster
 549 ### when constructed using "big" strings.  More than the C compiler, the awk
 550 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 551 AC_MSG_CHECKING(if big-strings option selected)
 552 AC_ARG_ENABLE(big-strings,
 553         [  --disable-big-strings   assume compiler has only standard-size strings],
 554         [with_big_strings=$enableval],
 555         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 556 AC_MSG_RESULT($with_big_strings)
 557
 558 USE_BIG_STRINGS=0
 559 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
 560 AC_SUBST(USE_BIG_STRINGS)
 561
 562 ###     use option --enable-termcap to compile in the termcap fallback support
 563 AC_MSG_CHECKING(if you want termcap-fallback support)
 564 AC_ARG_ENABLE(termcap,
 565         [  --enable-termcap        compile in termcap fallback support],
 566         [with_termcap=$enableval],
 567         [with_termcap=no])
 568 AC_MSG_RESULT($with_termcap)
 569
 570 if test "$with_termcap" != "yes" ; then
 571         if test "$use_database" = no ; then
 572                 if test -z "$with_fallback" ; then
 573                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 574                 fi
 575         fi
 576         AC_DEFINE(PURE_TERMINFO)
 577 else
 578
 579 if test "$with_ticlib" != no ; then
 580         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 581 fi
 582
 583 AC_DEFINE(USE_TERMCAP)
 584 AC_MSG_CHECKING(for list of termcap files)
 585 CF_WITH_PATHLIST(termpath,
 586         [  --with-termpath=XXX     specify list of termcap files],
 587         TERMPATH,
 588         /etc/termcap:/usr/share/misc/termcap)
 589 AC_MSG_RESULT($TERMPATH)
 590 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
 591
 592 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 593 AC_MSG_CHECKING(if fast termcap-loader is needed)
 594 AC_ARG_ENABLE(getcap,
 595         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 596         [with_getcap=$enableval],
 597         [with_getcap=no])
 598 AC_MSG_RESULT($with_getcap)
 599 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
 600
 601 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 602 AC_ARG_ENABLE(getcap-cache,
 603         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 604         [with_getcap_cache=$enableval],
 605         [with_getcap_cache=no])
 606 AC_MSG_RESULT($with_getcap_cache)
 607 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
 608
 609 fi
 610
 611 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 612 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 613 AC_ARG_ENABLE(home-terminfo,
 614         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 615         [with_home_terminfo=$enableval],
 616         [with_home_terminfo=yes])
 617 AC_MSG_RESULT($with_home_terminfo)
 618 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
 619
 620 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 621 AC_ARG_ENABLE(root-environ,
 622         [  --disable-root-environ  restrict environment when running as root],
 623         [with_root_environ=$enableval],
 624         [with_root_environ=yes])
 625 AC_MSG_RESULT($with_root_environ)
 626 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
 627
 628 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 629 ###   to reduce storage requirements for the terminfo database.
 630 CF_LINK_FUNCS
 631
 632 with_links=no
 633 with_symlinks=no
 634
 635 # soft links (symbolic links) are useful for some systems where hard links do
 636 # not work, or to make it simpler to copy terminfo trees around.
 637 if test "$ac_cv_func_symlink" = yes ; then
 638     AC_MSG_CHECKING(if tic should use symbolic links)
 639     AC_ARG_ENABLE(symlinks,
 640         [  --enable-symlinks       make tic use symbolic links not hard links],
 641         [with_symlinks=$enableval],
 642         [with_symlinks=no])
 643     AC_MSG_RESULT($with_symlinks)
 644 fi
 645
 646 # If we have hard links and did not choose to use soft links instead, there is
 647 # no reason to make this choice optional - use the hard links.
 648 if test "$with_symlinks" = no ; then
 649     AC_MSG_CHECKING(if tic should use hard links)
 650     if test "$ac_cv_func_link" = yes ; then
 651         with_links=yes
 652     else
 653         with_links=no
 654     fi
 655     AC_MSG_RESULT($with_links)
 656 fi
 657
 658 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
 659 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
 660
 661 ###   use option --enable-broken-linker to force on use of broken-linker support
 662 AC_MSG_CHECKING(if you want broken-linker support code)
 663 AC_ARG_ENABLE(broken_linker,
 664         [  --enable-broken_linker  compile with broken-linker support code],
 665         [with_broken_linker=$enableval],
 666         [with_broken_linker=${BROKEN_LINKER:-no}])
 667 AC_MSG_RESULT($with_broken_linker)
 668
 669 BROKEN_LINKER=0
 670 if test "$with_broken_linker" = yes ; then
 671         AC_DEFINE(BROKEN_LINKER)
 672         BROKEN_LINKER=1
 673 elif test "$DFT_LWR_MODEL" = shared ; then
 674         case $cf_cv_system_name in #(vi
 675         cygwin*)
 676                 AC_DEFINE(BROKEN_LINKER)
 677                 BROKEN_LINKER=1
 678                 CF_VERBOSE(cygwin linker is broken anyway)
 679                 ;;
 680         esac
 681 fi
 682 AC_SUBST(BROKEN_LINKER)
 683
 684 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 685 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 686 AC_ARG_ENABLE(bsdpad,
 687         [  --enable-bsdpad         recognize BSD-style prefix padding],
 688         [with_bsdpad=$enableval],
 689         [with_bsdpad=no])
 690 AC_MSG_RESULT($with_bsdpad)
 691 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
 692
 693 ###   use option --enable-widec to turn on use of wide-character support
 694 NCURSES_CH_T=chtype
 695 NCURSES_LIBUTF8=0
 696
 697 NEED_WCHAR_H=0
 698 NCURSES_MBSTATE_T=0
 699 NCURSES_WCHAR_T=0
 700 NCURSES_WINT_T=0
 701
 702 # Check to define _XOPEN_SOURCE "automatically"
 703 CF_XOPEN_SOURCE(500)
 704
 705 # Work around breakage on OS X
 706 CF_SIGWINCH
 707
 708 # Checks for CODESET support.
 709 AM_LANGINFO_CODESET
 710
 711 # use these variables to work around a defect in gcc's fixincludes.
 712 NCURSES_OK_WCHAR_T=
 713 NCURSES_OK_WINT_T=
 714
 715 AC_MSG_CHECKING(if you want wide-character code)
 716 AC_ARG_ENABLE(widec,
 717         [  --enable-widec          compile with wide-char/UTF-8 code],
 718         [with_widec=$enableval],
 719         [with_widec=no])
 720 AC_MSG_RESULT($with_widec)
 721 if test "$with_widec" = yes ; then
 722         LIB_SUFFIX="w${LIB_SUFFIX}"
 723         AC_DEFINE(USE_WIDEC_SUPPORT)
 724
 725         case "$CFLAGS $CPPFLAGS" in #(vi
 726         *-D_XOPEN_SOURCE=500) #(vi
 727                 ;;
 728         *)
 729                 CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 730                 ;;
 731         esac
 732
 733         # with_overwrite=no
 734         NCURSES_CH_T=cchar_t
 735         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 736         if test "$ac_cv_func_putwc" != yes ; then
 737                 CF_UTF8_LIB
 738                 if test "$cf_cv_utf8_lib" != no ; then
 739                         NCURSES_LIBUTF8=1
 740                 fi
 741         fi
 742         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 743         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 744         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 745
 746         if test "$NCURSES_MBSTATE_T" != 0; then
 747                 AC_DEFINE(NEED_MBSTATE_T_DEF)
 748         fi
 749 fi
 750 AC_SUBST(NCURSES_CH_T)
 751 AC_SUBST(NCURSES_LIBUTF8)
 752
 753 AC_SUBST(NEED_WCHAR_H)
 754 AC_SUBST(NCURSES_MBSTATE_T)
 755 AC_SUBST(NCURSES_WCHAR_T)
 756 AC_SUBST(NCURSES_WINT_T)
 757
 758 AC_SUBST(NCURSES_OK_WCHAR_T)
 759 AC_SUBST(NCURSES_OK_WINT_T)
 760
 761 ###   use option --disable-lp64 to allow long chtype
 762 case $cf_cv_abi_version in
 763 [[345]]*)
 764         default_with_lp64=no
 765         ;;
 766 *)
 767         default_with_lp64=yes
 768         ;;
 769 esac
 770
 771 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 772 AC_ARG_ENABLE(lp64,
 773         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 774         [with_lp64=$enableval],
 775         [with_lp64=$default_with_lp64])
 776 AC_MSG_RESULT($with_lp64)
 777
 778 if test "$with_lp64" = yes ; then
 779         cf_cv_enable_lp64=1
 780 else
 781         cf_cv_enable_lp64=0
 782 fi
 783 AC_SUBST(cf_cv_enable_lp64)
 784
 785 CF_LARGEFILE
 786
 787 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 788 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 789 AC_ARG_ENABLE(tparm-varargs,
 790         [  --disable-tparm-varargs compile tparm() without varargs interface],
 791         [with_tparm_varargs=$enableval],
 792         [with_tparm_varargs=yes])
 793 AC_MSG_RESULT($with_tparm_varargs)
 794 NCURSES_TPARM_VARARGS=0
 795 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
 796 AC_SUBST(NCURSES_TPARM_VARARGS)
 797
 798 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 799 if test "$with_ticlib" != no ; then
 800 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 801 AC_ARG_ENABLE(tic-depends,
 802         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 803         [with_tic_depends=$enableval],
 804         [with_tic_depends=yes])
 805 AC_MSG_RESULT($with_tic_depends)
 806 else
 807         with_tic_depends=no
 808 fi
 809
 810 ###   use option --with-bool to override bool's type
 811 AC_MSG_CHECKING(for type of bool)
 812 AC_ARG_WITH(bool,
 813         [  --with-bool=TYPE        override fallback type of bool variable],
 814         [NCURSES_BOOL="$withval"],
 815         [NCURSES_BOOL=auto])
 816 AC_MSG_RESULT($NCURSES_BOOL)
 817 AC_SUBST(NCURSES_BOOL)
 818
 819 AC_MSG_CHECKING(for alternate terminal capabilities file)
 820 AC_ARG_WITH(caps,
 821         [  --with-caps=alt         compile with alternate Caps file],
 822         [TERMINFO_CAPS=Caps.$withval],
 823         [TERMINFO_CAPS=Caps])
 824 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 825 AC_MSG_RESULT($TERMINFO_CAPS)
 826 AC_SUBST(TERMINFO_CAPS)
 827
 828 ###   use option --with-chtype to override chtype's type
 829 AC_MSG_CHECKING(for type of chtype)
 830 AC_ARG_WITH(chtype,
 831         [  --with-chtype=TYPE      override type of chtype],
 832         [NCURSES_CHTYPE="$withval"],
 833         [NCURSES_CHTYPE=auto])
 834 AC_MSG_RESULT($NCURSES_CHTYPE)
 835
 836 ###   use option --with-ospeed to override ospeed's type
 837 AC_MSG_CHECKING(for type of ospeed)
 838 AC_ARG_WITH(ospeed,
 839         [  --with-ospeed=TYPE      override type of ospeed variable],
 840         [NCURSES_OSPEED="$withval"],
 841         [NCURSES_OSPEED=short])
 842 AC_MSG_RESULT($NCURSES_OSPEED)
 843 AC_SUBST(NCURSES_OSPEED)
 844
 845 ###   use option --with-mmask-t to override mmask_t's type
 846 AC_MSG_CHECKING(for type of mmask_t)
 847 AC_ARG_WITH(mmask-t,
 848         [  --with-mmask-t=TYPE     override type of mmask_t],
 849         [NCURSES_MMASK_T="$withval"],
 850         [NCURSES_MMASK_T=auto])
 851 AC_MSG_RESULT($NCURSES_MMASK_T)
 852
 853 ###   use option --with-ccharw-max to override CCHARW_MAX size
 854 AC_MSG_CHECKING(for size CCHARW_MAX)
 855 AC_ARG_WITH(ccharw-max,
 856         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
 857         [NCURSES_CCHARW_MAX="$withval"],
 858         [NCURSES_CCHARW_MAX=5])
 859 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
 860 AC_SUBST(NCURSES_CCHARW_MAX)
 861
 862 ### Enable compiling-in rcs id's
 863 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
 864 AC_ARG_WITH(rcs-ids,
 865         [  --with-rcs-ids          compile-in RCS identifiers],
 866         [with_rcs_ids=$withval],
 867         [with_rcs_ids=no])
 868 AC_MSG_RESULT($with_rcs_ids)
 869 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
 870
 871 ###############################################################################
 872 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
 873
 874 ###############################################################################
 875 CF_HELP_MESSAGE(Extensions:)
 876
 877 ### Note that some functions (such as const) are normally disabled anyway.
 878 AC_MSG_CHECKING(if you want to build with function extensions)
 879 AC_ARG_ENABLE(ext-funcs,
 880         [  --disable-ext-funcs     disable function-extensions],
 881         [with_ext_funcs=$enableval],
 882         [with_ext_funcs=yes])
 883 AC_MSG_RESULT($with_ext_funcs)
 884 if test "$with_ext_funcs" = yes ; then
 885         NCURSES_EXT_FUNCS=1
 886         AC_DEFINE(HAVE_CURSES_VERSION)
 887         AC_DEFINE(HAVE_HAS_KEY)
 888         AC_DEFINE(HAVE_RESIZETERM)
 889         AC_DEFINE(HAVE_RESIZE_TERM)
 890         AC_DEFINE(HAVE_TERM_ENTRY_H)
 891         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
 892         AC_DEFINE(HAVE_WRESIZE)
 893         AC_DEFINE(NCURSES_EXT_FUNCS)
 894         GENERATED_EXT_FUNCS=generated
 895 else
 896         NCURSES_EXT_FUNCS=0
 897         GENERATED_EXT_FUNCS=
 898 fi
 899 AC_SUBST(NCURSES_EXT_FUNCS)
 900 AC_SUBST(GENERATED_EXT_FUNCS)
 901
 902 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
 903 AC_ARG_ENABLE(sp-funcs,
 904         [  --enable-sp-funcs       enable experimental SCREEN-extensions],
 905         [with_sp_funcs=$enableval],
 906         [with_sp_funcs=no])
 907 AC_MSG_RESULT($with_sp_funcs)
 908 if test "$with_sp_funcs" = yes ; then
 909         NCURSES_SP_FUNCS=1
 910         AC_DEFINE(NCURSES_SP_FUNCS)
 911         GENERATED_SP_FUNCS=generated
 912 else
 913         NCURSES_SP_FUNCS=0
 914         GENERATED_SP_FUNCS=
 915 fi
 916 AC_SUBST(NCURSES_SP_FUNCS)
 917 AC_SUBST(GENERATED_SP_FUNCS)
 918
 919 AC_MSG_CHECKING(if you want to build with experimental terminal-driver)
 920 AC_ARG_ENABLE(term-driver,
 921         [  --enable-term-driver    enable experimental terminal-driver],
 922         [with_term_driver=$enableval],
 923         [with_term_driver=no])
 924 AC_MSG_RESULT($with_term_driver)
 925 if test "$with_term_driver" = yes ; then
 926         AC_DEFINE(USE_TERM_DRIVER)
 927         if test "$with_sp_funcs" != yes ; then
 928                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
 929         fi
 930 fi
 931
 932 ###   use option --enable-const to turn on use of const beyond that in XSI.
 933 AC_MSG_CHECKING(for extended use of const keyword)
 934 AC_ARG_ENABLE(const,
 935         [  --enable-const          compile with extra/non-standard const],
 936         [with_ext_const=$enableval],
 937         [with_ext_const=no])
 938 AC_MSG_RESULT($with_ext_const)
 939 NCURSES_CONST='/*nothing*/'
 940 if test "$with_ext_const" = yes ; then
 941         NCURSES_CONST=const
 942 fi
 943 AC_SUBST(NCURSES_CONST)
 944
 945 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
 946 AC_MSG_CHECKING(if you want to use extended colors)
 947 AC_ARG_ENABLE(ext-colors,
 948         [  --enable-ext-colors     compile for 256-color support],
 949         [with_ext_colors=$enableval],
 950         [with_ext_colors=no])
 951 AC_MSG_RESULT($with_ext_colors)
 952 NCURSES_EXT_COLORS=0
 953 if test "$with_ext_colors" = yes ; then
 954         if test "$with_widec" != yes ; then
 955                 AC_MSG_ERROR(This option applies only to wide-character library)
 956         else
 957                 # cannot be ABI 5 since it changes sizeof(cchar_t)
 958                 CF_NCURSES_ABI_6
 959         fi
 960         NCURSES_EXT_COLORS=1
 961         AC_DEFINE(NCURSES_EXT_COLORS)
 962 fi
 963 AC_SUBST(NCURSES_EXT_COLORS)
 964
 965 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
 966 AC_MSG_CHECKING(if you want to use extended mouse encoding)
 967 AC_ARG_ENABLE(ext-mouse,
 968         [  --enable-ext-mouse      compile for extended mouse-encoding],
 969         [with_ext_mouse=$enableval],
 970         [with_ext_mouse=no])
 971 AC_MSG_RESULT($with_ext_mouse)
 972 NCURSES_MOUSE_VERSION=1
 973 if test "$with_ext_mouse" = yes ; then
 974         NCURSES_MOUSE_VERSION=2
 975         CF_NCURSES_ABI_6
 976 fi
 977 AC_SUBST(NCURSES_MOUSE_VERSION)
 978
 979 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
 980 AC_ARG_ENABLE(no-padding,
 981         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
 982         [with_no_padding=$enableval],
 983         [with_no_padding=$with_ext_funcs])
 984 AC_MSG_RESULT($with_no_padding)
 985 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
 986
 987 AC_CHECK_SIZEOF([signed char], 0)
 988 if test "$ac_cv_sizeof_signed_char" = 1 ; then
 989         NCURSES_SBOOL="signed char"
 990 else
 991         NCURSES_SBOOL="char"
 992 fi
 993 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
 994 AC_ARG_ENABLE(signed-char,
 995         [  --enable-signed-char    compile using signed Boolean's in term.h],
 996         [with_signed_char=$enableval],
 997         [with_signed_char=no])
 998 AC_MSG_RESULT($with_signed_char)
 999 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
1000 AC_SUBST(NCURSES_SBOOL)
1001
1002 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1003 AC_MSG_CHECKING(if you want SIGWINCH handler)
1004 AC_ARG_ENABLE(sigwinch,
1005         [  --enable-sigwinch       compile with SIGWINCH handler],
1006         [with_sigwinch=$enableval],
1007         [with_sigwinch=$with_ext_funcs])
1008 AC_MSG_RESULT($with_sigwinch)
1009 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
1010
1011 ###   use option --enable-tcap-names to allow user to define new capabilities
1012 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1013 AC_ARG_ENABLE(tcap-names,
1014         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1015         [with_tcap_names=$enableval],
1016         [with_tcap_names=$with_ext_funcs])
1017 AC_MSG_RESULT($with_tcap_names)
1018 NCURSES_XNAMES=0
1019 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
1020 AC_SUBST(NCURSES_XNAMES)
1021
1022 ###############################################################################
1023 # These options are relatively safe to experiment with.
1024 CF_HELP_MESSAGE(Development Code:)
1025 AC_MSG_CHECKING(if you want all development code)
1026 AC_ARG_WITH(develop,
1027         [  --without-develop       disable development options],
1028         [with_develop=$withval],
1029         [with_develop=no])
1030 AC_MSG_RESULT($with_develop)
1031
1032 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1033 AC_MSG_CHECKING(if you want hard-tabs code)
1034 AC_ARG_ENABLE(hard-tabs,
1035         [  --enable-hard-tabs      compile with hard-tabs code],,
1036         [enable_hard_tabs=$with_develop])
1037 AC_MSG_RESULT($enable_hard_tabs)
1038 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
1039
1040 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1041 AC_MSG_CHECKING(if you want limited support for xmc)
1042 AC_ARG_ENABLE(xmc-glitch,
1043         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1044         [enable_xmc_glitch=$with_develop])
1045 AC_MSG_RESULT($enable_xmc_glitch)
1046 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
1047
1048 ###############################################################################
1049 # These are just experimental, probably should not be in a package:
1050 CF_HELP_MESSAGE(Experimental Code:)
1051
1052 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1053 AC_ARG_ENABLE(assumed-color,
1054         [  --disable-assumed-color do not assume anything about default-colors],
1055         [with_assumed_color=$enableval],
1056         [with_assumed_color=yes])
1057 AC_MSG_RESULT($with_assumed_color)
1058 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
1059
1060 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1061 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1062 AC_ARG_ENABLE(hashmap,
1063         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1064         [with_hashmap=$enableval],
1065         [with_hashmap=yes])
1066 AC_MSG_RESULT($with_hashmap)
1067 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
1068
1069 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1070 AC_MSG_CHECKING(if you want colorfgbg code)
1071 AC_ARG_ENABLE(colorfgbg,
1072         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1073         [with_colorfgbg=$enableval],
1074         [with_colorfgbg=no])
1075 AC_MSG_RESULT($with_colorfgbg)
1076 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
1077
1078 ###   use option --enable-interop to turn on use of bindings used for interop
1079 AC_MSG_CHECKING(if you want interop bindings)
1080 AC_ARG_ENABLE(interop,
1081         [  --enable-interop        compile-in experimental interop bindings],
1082         [with_exp_interop=$enableval],
1083         [with_exp_interop=no])
1084 AC_MSG_RESULT($with_exp_interop)
1085
1086 NCURSES_INTEROP_FUNCS=0
1087 test "$with_exp_interop" = yes && NCURSES_INTEROP_FUNCS=1
1088 AC_SUBST(NCURSES_INTEROP_FUNCS)
1089
1090 # This is still experimental (20080329), but should ultimately be moved to
1091 # the script-block --with-normal, etc.
1092 CF_WITH_PTHREAD
1093
1094 if test "x$with_pthread" != xno; then
1095         AC_CHECK_FUNC(pthread_kill,[
1096                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1097                 AC_ARG_ENABLE(pthreads-eintr,
1098                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1099                         [use_pthreads_eintr=$enableval],
1100                         [use_pthreads_eintr=no])
1101                 AC_MSG_RESULT($use_pthreads_eintr)
1102                 if test $use_pthreads_eintr = yes ; then
1103                         AC_DEFINE(USE_PTHREADS_EINTR)
1104                 fi])
1105
1106         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1107         AC_ARG_ENABLE(weak-symbols,
1108                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1109                 [use_weak_symbols=$enableval],
1110                 [use_weak_symbols=no])
1111         AC_MSG_RESULT($use_weak_symbols)
1112         if test "$use_weak_symbols" = yes ; then
1113                 CF_WEAK_SYMBOLS
1114         else
1115                 cf_cv_weak_symbols=no
1116         fi
1117
1118         if test $cf_cv_weak_symbols = yes ; then
1119                 AC_DEFINE(USE_WEAK_SYMBOLS)
1120         fi
1121 fi
1122
1123 PTHREAD=
1124 if test "$with_pthread" = "yes" ; then
1125     AC_DEFINE(USE_PTHREADS)
1126     enable_reentrant=yes
1127     if test $cf_cv_weak_symbols = yes ; then
1128         PTHREAD=-lpthread
1129     fi
1130 fi
1131 AC_SUBST(PTHREAD)
1132
1133 # Reentrant code has to be opaque; there's little advantage to making ncurses
1134 # opaque outside of that, so there is no --enable-opaque option.  We can use
1135 # this option without --with-pthreads, but this will be always set for
1136 # pthreads.
1137 AC_MSG_CHECKING(if you want experimental reentrant code)
1138 AC_ARG_ENABLE(reentrant,
1139         [  --enable-reentrant      compile with experimental reentrant code],
1140         [with_reentrant=$enableval],
1141         [with_reentrant=no])
1142 AC_MSG_RESULT($with_reentrant)
1143 if test "$with_reentrant" = yes ; then
1144         cf_cv_enable_reentrant=1
1145         cf_cv_enable_opaque="NCURSES_INTERNALS"
1146         NCURSES_OPAQUE=1
1147         NCURSES_SIZE_T=int
1148         if test $cf_cv_weak_symbols = yes ; then
1149                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1150                 CF_ADD_LIB(pthread,TEST_LIBS)
1151                 CF_ADD_LIB(pthread,TEST_LIBS2)
1152         else
1153                 LIB_SUFFIX="t${LIB_SUFFIX}"
1154         fi
1155         AC_DEFINE(USE_REENTRANT)
1156         CF_NCURSES_ABI_6
1157 else
1158         cf_cv_enable_reentrant=0
1159         cf_cv_enable_opaque="NCURSES_OPAQUE"
1160         NCURSES_OPAQUE=0
1161         NCURSES_SIZE_T=short
1162 fi
1163 AC_SUBST(cf_cv_enable_reentrant)
1164 AC_SUBST(cf_cv_enable_opaque)
1165 AC_SUBST(NCURSES_OPAQUE)
1166 AC_SUBST(NCURSES_SIZE_T)
1167
1168 ### Allow using a different wrap-prefix
1169 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1170         AC_MSG_CHECKING(for prefix used to wrap public variables)
1171         AC_ARG_WITH(wrap-prefix,
1172                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1173                 [NCURSES_WRAP_PREFIX=$withval],
1174                 [NCURSES_WRAP_PREFIX=_nc_])
1175         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1176 else
1177         NCURSES_WRAP_PREFIX=_nc_
1178 fi
1179 AC_SUBST(NCURSES_WRAP_PREFIX)
1180 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX")
1181
1182 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1183 AC_ARG_ENABLE(safe-sprintf,
1184         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1185         [with_safe_sprintf=$enableval],
1186         [with_safe_sprintf=no])
1187 AC_MSG_RESULT($with_safe_sprintf)
1188 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1189
1190 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1191 # when hashmap is used scroll hints are useless
1192 if test "$with_hashmap" = no ; then
1193 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1194 AC_ARG_ENABLE(scroll-hints,
1195         [  --disable-scroll-hints  compile without scroll-hints code],
1196         [with_scroll_hints=$enableval],
1197         [with_scroll_hints=yes])
1198 AC_MSG_RESULT($with_scroll_hints)
1199 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1200 fi
1201
1202 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1203 AC_ARG_ENABLE(wgetch-events,
1204         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1205         [with_wgetch_events=$enableval],
1206         [with_wgetch_events=no])
1207 AC_MSG_RESULT($with_wgetch_events)
1208 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1209
1210 ###############################################################################
1211 CF_HELP_MESSAGE(Testing/development Options:)
1212
1213 ###     use option --disable-echo to suppress full display compiling commands
1214 AC_MSG_CHECKING(if you want to display full commands during build)
1215 AC_ARG_ENABLE(echo,
1216         [  --enable-echo           build: display "compiling" commands (default)],
1217         [with_echo=$enableval],
1218         [with_echo=yes])
1219 if test "$with_echo" = yes; then
1220         ECHO_LINK=
1221 else
1222         ECHO_LINK='@ echo linking $@ ... ;'
1223         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1224         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1225 fi
1226 AC_MSG_RESULT($with_echo)
1227 AC_SUBST(ECHO_LINK)
1228
1229 ###     use option --enable-warnings to turn on all gcc warnings
1230 AC_MSG_CHECKING(if you want to see compiler warnings)
1231 AC_ARG_ENABLE(warnings,
1232         [  --enable-warnings       build: turn on GCC compiler warnings],
1233         [with_warnings=$enableval])
1234 AC_MSG_RESULT($with_warnings)
1235
1236 if test "x$with_warnings" = "xyes"; then
1237         CF_ADD_ADAFLAGS(-gnatg)
1238         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1239         if test "$cf_with_cxx" = yes ; then
1240                 CF_GXX_WARNINGS(Wno-unused)
1241         fi
1242 fi
1243 CF_GCC_ATTRIBUTES
1244
1245 ###     use option --enable-assertions to turn on generation of assertion code
1246 AC_MSG_CHECKING(if you want to enable runtime assertions)
1247 AC_ARG_ENABLE(assertions,
1248         [  --enable-assertions     test: turn on generation of assertion code],
1249         [with_assertions=$enableval],
1250         [with_assertions=no])
1251 AC_MSG_RESULT($with_assertions)
1252 if test -n "$GCC"
1253 then
1254         if test "$with_assertions" = no
1255         then
1256                 AC_DEFINE(NDEBUG)
1257                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1258         else
1259                 CF_ADD_ADAFLAGS(-gnata)
1260         fi
1261 fi
1262
1263 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1264 CF_DISABLE_LEAKS
1265 AC_DEFINE(HAVE_NC_ALLOC_H)
1266
1267 ###     use option --enable-expanded to generate certain macros as functions
1268 AC_ARG_ENABLE(expanded,
1269         [  --enable-expanded       test: generate functions for certain macros],
1270         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1271
1272 ###     use option --disable-macros to suppress macros in favor of functions
1273 AC_ARG_ENABLE(macros,
1274         [  --disable-macros        test: use functions rather than macros],
1275         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1276
1277 # Normally we only add trace() to the debug-library.  Allow this to be
1278 # extended to all models of the ncurses library:
1279 cf_all_traces=no
1280 case "$CFLAGS $CPPFLAGS" in
1281 *-DTRACE*)
1282         cf_all_traces=yes
1283         ;;
1284 esac
1285
1286 AC_MSG_CHECKING(whether to add trace feature to all models)
1287 AC_ARG_WITH(trace,
1288 [  --with-trace            test: add trace() function to all models of ncurses],
1289 [cf_with_trace=$withval],
1290 [cf_with_trace=$cf_all_traces])
1291 AC_MSG_RESULT($cf_with_trace)
1292
1293 if test "$cf_with_trace" = yes ; then
1294         LIB_TRACING=all
1295         ADA_TRACE=TRUE
1296         CF_ADD_CFLAGS(-DTRACE)
1297 else
1298         LIB_TRACING=DEBUG
1299         ADA_TRACE=FALSE
1300 fi
1301
1302 AC_SUBST(ADA_TRACE)
1303
1304 ###     Checks for libraries.
1305 case $cf_cv_system_name in #(vi
1306 *mingw32*) #(vi
1307         ;;
1308 *)
1309 AC_CHECK_FUNC(gettimeofday,
1310         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1311
1312 AC_CHECK_LIB(bsd, gettimeofday,
1313         AC_DEFINE(HAVE_GETTIMEOFDAY)
1314         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1315         ;;
1316 esac
1317
1318 CF_MATH_LIB(MATH_LIB,sin(x))
1319 AC_SUBST(MATH_LIB)
1320
1321 ###     Checks for header files.
1322 AC_STDC_HEADERS
1323 AC_HEADER_DIRENT
1324 AC_HEADER_TIME
1325 CF_REGEX
1326
1327 dnl These are some other potentially nonportable headers.
1328 AC_CHECK_HEADERS( \
1329 fcntl.h \
1330 getopt.h \
1331 limits.h \
1332 locale.h \
1333 math.h \
1334 poll.h \
1335 sys/bsdtypes.h \
1336 sys/ioctl.h \
1337 sys/param.h \
1338 sys/poll.h \
1339 sys/select.h \
1340 sys/time.h \
1341 sys/times.h \
1342 ttyent.h \
1343 unistd.h \
1344 wctype.h \
1345 )
1346
1347 # check for ISC (this may also define _POSIX_SOURCE)
1348 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1349 if test "$ISC" = yes ; then
1350         AC_CHECK_LIB(cposix,main)
1351         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1352 fi
1353
1354 CF_SYS_TIME_SELECT
1355
1356 ###     checks for compiler characteristics
1357 AC_LANG_C
1358 AC_C_CONST
1359 CF_C_INLINE(NCURSES_INLINE,1200)
1360 CF_SIG_ATOMIC_T
1361
1362 if test $NCURSES_CHTYPE = auto ; then
1363         CF_TYPEOF_CHTYPE
1364 else
1365         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1366 fi
1367 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1368 AC_SUBST(cf_cv_typeof_chtype)
1369
1370 CF_UNSIGNED_LITERALS
1371 cf_cv_1UL="1"
1372 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1373 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1374 AC_SUBST(cf_cv_1UL)
1375
1376 if test $NCURSES_MMASK_T = auto ; then
1377         cf_cv_typeof_mmask_t=long
1378 else
1379         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1380 fi
1381 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1382 AC_SUBST(cf_cv_typeof_mmask_t)
1383
1384 ###     Checks for external-data
1385 CF_ERRNO
1386 CF_LINK_DATAONLY
1387
1388 ###     Checks for library functions.
1389 AC_CHECK_FUNCS( \
1390 getcwd \
1391 getegid \
1392 geteuid \
1393 getttynam \
1394 issetugid \
1395 poll \
1396 remove \
1397 select \
1398 setbuf \
1399 setbuffer \
1400 setvbuf \
1401 sigaction \
1402 sigvec \
1403 strdup \
1404 strstr \
1405 tcgetpgrp \
1406 times \
1407 vsnprintf \
1408 )
1409 if test "$with_getcap" = "yes" ; then
1410         CF_CGETENT
1411 fi
1412
1413 CF_ISASCII
1414 CF_STRUCT_SIGACTION
1415 CF_FUNC_NANOSLEEP
1416 CF_FUNC_TERMIOS
1417 CF_FUNC_VSSCANF
1418 CF_MKSTEMP
1419
1420 # setup for prototype of fallback for vsscanf()
1421 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1422
1423 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1424 if test "$cross_compiling" = yes ; then
1425         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1426 else
1427         AC_FUNC_SETVBUF_REVERSED
1428 fi
1429 AC_TYPE_SIGNAL
1430 CF_TYPE_SIGACTION
1431 CF_SIZECHANGE
1432 CF_FUNC_MEMMOVE
1433 CF_FUNC_POLL
1434 CF_VA_COPY
1435 AC_FUNC_VFORK
1436
1437 # special check for test/ditto.c
1438 CF_FUNC_OPENPTY
1439 if test "$cf_cv_func_openpty" != no ; then
1440     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1441     AC_DEFINE(USE_XTERM_PTY)
1442     if test "$cf_cv_lib_util" = yes ; then
1443         CF_ADD_LIB(util,TEST_LIBS)
1444     fi
1445 fi
1446 AC_SUBST(TEST_LIBS)
1447 AC_SUBST(TEST_LIBS2)
1448
1449 if test "$with_hashed_db" != no ; then
1450         AC_DEFINE(USE_HASHED_DB)
1451         CF_HASHED_DB($with_hashed_db)
1452 fi
1453
1454 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1455 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1456         CF_STRIP_G_OPT(CFLAGS)
1457         CF_STRIP_G_OPT(CXXFLAGS)
1458 fi
1459
1460 # Just in case, check if the C compiler has a bool type.
1461 CF_BOOL_DECL(cf_cv_cc_bool_type)
1462
1463 # Check for C++ compiler characteristics (and ensure that it's there!)
1464 if test -n "$CXX" ; then
1465         AC_LANG_CPLUSPLUS
1466         CF_STDCPP_LIBRARY
1467         CF_PROG_CC_C_O(CXX)
1468
1469         case $GXX_VERSION in
1470         1*|2.[0-6]*)
1471                 cf_cxx_library=yes
1472                 ;;
1473         *-2.7*|2.7*)
1474                 CF_GPP_LIBRARY
1475                 ;;
1476         *)
1477                 cf_cxx_library=no
1478                 ;;
1479         esac
1480
1481         AC_CHECK_HEADERS(iostream typeinfo)
1482
1483     if test x"$ac_cv_header_iostream" = xyes ; then
1484         AC_MSG_CHECKING(if iostream uses std-namespace)
1485         AC_TRY_COMPILE([
1486 #include <iostream>
1487 using std::endl;
1488 using std::cerr;],[
1489 cerr << "testing" << endl;
1490 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1491         AC_MSG_RESULT($cf_iostream_namespace)
1492         if test "$cf_iostream_namespace" = yes ; then
1493             AC_DEFINE(IOSTREAM_NAMESPACE)
1494         fi
1495     fi
1496
1497         CF_BOOL_DECL
1498         CF_BOOL_SIZE
1499         CF_ETIP_DEFINES
1500         CF_CPP_PARAM_INIT
1501         CF_CPP_STATIC_CAST
1502
1503         CXX_AR='$(AR)'
1504         CXX_ARFLAGS='$(ARFLAGS)'
1505         case $cf_cv_system_name in #(vi
1506         irix*) #(vi
1507             if test "$GXX" != yes ; then
1508                 CXX_AR='$(CXX)'
1509                 CXX_ARFLAGS='-ar -o'
1510             fi
1511             ;;
1512         sco3.2v5*) #(vi
1513             CXXLDFLAGS="-u main"
1514             ;;
1515         solaris2*)
1516             if test "$GXX" != yes ; then
1517                 CXX_AR='$(CXX)'
1518                 CXX_ARFLAGS='-xar -o'
1519             fi
1520             ;;
1521         esac
1522         AC_SUBST(CXXLDFLAGS)
1523         AC_SUBST(CXX_AR)
1524         AC_SUBST(CXX_ARFLAGS)
1525 else
1526         cf_cxx_library=no
1527         cf_cv_builtin_bool=1
1528
1529         # Just because we are not configuring against C++ right now does not
1530         # mean that a user will not want to use C++.  Some distributors disable
1531         # the C++ portion of this configuration as a shortcut (or just to avoid
1532         # compiling the demo in the c++ directory).  So we need a reasonable
1533         # default for the 'bool' type.
1534         #
1535         # Caveat: since the storage of the bool type is not standardized, it
1536         # may change.
1537
1538         if test "$NCURSES_BOOL" != auto ; then
1539                 cf_cv_type_of_bool=$NCURSES_BOOL
1540                 cf_cv_header_stdbool_h=0
1541         else
1542                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1543                         CF_BOOL_SIZE
1544                 else
1545                         AC_MSG_CHECKING(for fallback type of bool)
1546                         case "$host_cpu" in #(vi
1547                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1548                         *)      cf_cv_type_of_bool=int  ;;
1549                         esac
1550                         AC_MSG_RESULT($cf_cv_type_of_bool)
1551                 fi
1552         fi
1553 fi
1554 AC_SUBST(CXXLIBS)
1555
1556 # If the C compiler did not declare bool, and we did not determine that the C++
1557 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1558 # ncurses library use the same type as C++ bool.  Note that this allows one to
1559 # specify the type of bool in a configure-script option and postpone
1560 # integration with the C++ compiler provided that the types are compatible.
1561 USE_CXX_BOOL=1
1562 if test $cf_cv_cc_bool_type = 1
1563 then
1564         # oops: C has a bool.  Unlikely, but C++ could differ.
1565         USE_CXX_BOOL=0
1566 elif test $cf_cv_builtin_bool = 0
1567 then
1568         # C++ has no bool
1569         USE_CXX_BOOL=0
1570 else
1571         # this is the normal case
1572         USE_CXX_BOOL='defined(__cplusplus)'
1573 fi
1574 AC_SUBST(USE_CXX_BOOL)
1575
1576 CF_HELP_MESSAGE(Ada95 Binding Options:)
1577
1578 dnl If the Ada95 source-tree is present, add that to the build unless it will
1579 dnl not work, or was not requested.
1580 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1581
1582 dnl libtool does not know anything about GNAT, though a change made in 1998
1583 dnl provided for it "someday".  Disable the ada subtree if we are using
1584 dnl libtool -TD 20070714
1585         if test "$cf_with_ada" != "no" ; then
1586                 if test "$with_libtool" != "no"; then
1587                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1588                         cf_with_ada=no
1589                 fi
1590         fi
1591
1592 dnl Check for availability of GNU Ada Translator (GNAT).
1593 dnl At the moment we support no other Ada95 compiler.
1594         if test "$cf_with_ada" != "no" ; then
1595                 CF_PROG_GNAT
1596                 if test "$cf_cv_prog_gnat_correct" = yes; then
1597                         CF_ADD_ADAFLAGS(-gnatpn)
1598
1599                         # make ADAFLAGS consistent with CFLAGS
1600                         case "$CFLAGS" in
1601                         *-g*)
1602                                 CF_ADD_ADAFLAGS(-g)
1603                                 ;;
1604                         esac
1605                         case "$CFLAGS" in
1606                         *-O*)
1607                                 CF_ADD_ADAFLAGS(-O3)
1608                                 ;;
1609                         esac
1610
1611                         CF_GNAT_GENERICS
1612                         CF_GNAT_SIGINT
1613                         CF_GNAT_PRAGMA_UNREF
1614                         CF_GNAT_PROJECTS
1615
1616                         CF_WITH_ADA_COMPILER
1617
1618                         cf_ada_package=terminal_interface
1619                         AC_SUBST(cf_ada_package)
1620
1621                         CF_WITH_ADA_INCLUDE
1622                         CF_WITH_ADA_OBJECTS
1623                         CF_WITH_ADA_SHAREDLIB
1624                 fi
1625         fi
1626 else
1627         cf_with_ada=no
1628 fi
1629
1630 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1631 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1632 ###
1633 ### ticlib modules may be a separate library, otherwise contained in termlib.
1634 ### termlib modules may be a separate library, otherwise contained in ncurses.
1635 ###
1636 ### The of "+" or " " between the tokens controls the way the script
1637 ### chooses to split module lists into libraries.
1638 ###
1639 ### (see CF_LIB_RULES).
1640 AC_MSG_CHECKING(for library subsets)
1641 LIB_SUBSETS=
1642
1643 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1644         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1645         if test "$with_ticlib" != no ; then
1646                 LIB_SUBSETS="${LIB_SUBSETS} "
1647         else
1648                 LIB_SUBSETS="${LIB_SUBSETS}+"
1649         fi
1650 fi
1651
1652 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1653 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1654
1655 if test "$with_termlib" != no ; then
1656         LIB_SUBSETS="${LIB_SUBSETS} "
1657 else
1658         LIB_SUBSETS="${LIB_SUBSETS}+"
1659 fi
1660
1661 LIB_SUBSETS="${LIB_SUBSETS}base"
1662
1663 # Most term-driver calls are to tinfo, but some like init_pair are to the
1664 # base library (so it resides in base).
1665 if test "$with_term_driver" != no ; then
1666         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1667         case $cf_cv_system_name in #(vi
1668         *mingw32*) #(vi
1669                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1670                 ;;
1671         *) #(vi
1672                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1673                 ;;
1674         esac
1675 fi
1676
1677 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1678 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1679
1680 AC_MSG_RESULT($LIB_SUBSETS)
1681
1682 ### Construct the list of include-directories to be generated
1683 CF_INCLUDE_DIRS
1684 CF_ADA_INCLUDE_DIRS
1685
1686 ### Build up pieces for makefile rules
1687 AC_MSG_CHECKING(default library suffix)
1688 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1689 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1690 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1691
1692 AC_MSG_CHECKING(default library-dependency suffix)
1693 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1694 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1695 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1696
1697 AC_MSG_CHECKING(default object directory)
1698 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1699 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1700 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1701
1702 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1703 if test "$cf_with_cxx" = yes ; then
1704 AC_MSG_CHECKING(c++ library-dependency suffix)
1705 if test "$with_libtool" != "no"; then
1706         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1707 else
1708         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)dnl we normally make a static library
1709 fi
1710 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1711 AC_SUBST(CXX_LIB_SUFFIX)
1712 fi
1713
1714 # do not want -ldl in build except as needed for -lncurses dependency
1715 if test "$with_dlsym" = yes ; then
1716 if test $DFT_LWR_MODEL = shared || \
1717    test $DFT_LWR_MODEL = libtool ; then
1718         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1719 fi
1720 fi
1721 ### Set up low-level terminfo dependencies for makefiles.
1722
1723 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1724 # do not need libdl
1725 TICS_LIST=
1726 if test "$with_dlsym" = yes ; then
1727         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1728 fi
1729
1730 if test "$with_ticlib" != no ; then
1731
1732         if test "$with_ticlib" != yes ; then
1733                 TICS_NAME=$with_ticlib
1734                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1735                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1736                 TICS_LIB_SUFFIX="${with_ticlib}"
1737         else
1738                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1739                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1740                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1741         fi
1742         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1743 else
1744         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1745 fi
1746 AC_SUBST(TICS_ARG_SUFFIX)
1747 AC_SUBST(TICS_DEP_SUFFIX)
1748 AC_SUBST(TICS_LIB_SUFFIX)
1749 AC_SUBST(TICS_ARGS)
1750
1751 if test "$with_termlib" != no ; then
1752
1753         if test "$with_termlib" != yes ; then
1754                 TINFO_NAME=$with_termlib
1755                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1756                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1757                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1758                 TINFO_LIB_SUFFIX="${with_termlib}"
1759         else
1760                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1761                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1762                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1763                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1764         fi
1765
1766         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1767         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1768         if test "$DFT_LWR_MODEL" = "libtool"; then
1769                 TEST_ARGS="${TEST_DEPS}"
1770                 TEST_ARG2="${TEST_DEP2}"
1771                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1772                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1773                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1774         else
1775                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1776                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1777                 TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1778                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1779                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1780         fi
1781 else
1782         # the next lines are needed for linking libtic over libncurses
1783         TINFO_NAME=${LIB_NAME}
1784         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1785         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1786         if test "$with_tic_depends" = yes ; then
1787                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1788         else
1789                 TICS_LIST="$SHLIB_LIST"
1790         fi
1791
1792         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1793 fi
1794
1795 if test "$DFT_LWR_MODEL" = shared ; then
1796         case $cf_cv_system_name in #(vi
1797         cygwin*)
1798                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1799                 TINFO_SUFFIX=.dll
1800                 ;;
1801         esac
1802 fi
1803
1804 AC_SUBST(TINFO_ARG_SUFFIX)
1805 AC_SUBST(TINFO_DEP_SUFFIX)
1806 AC_SUBST(TINFO_LIB_SUFFIX)
1807 AC_SUBST(TINFO_ARGS)
1808
1809 if test "$with_dlsym" = yes ; then
1810         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1811 fi
1812
1813 if test "$DFT_LWR_MODEL" = "libtool"; then
1814     OBJEXT=lo
1815 fi
1816
1817 # needed for Ada95
1818 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1819 AC_SUBST(TINFO_ARGS2)
1820
1821 case $DFT_LWR_MODEL in
1822 normal|debug|profile)
1823         CF_LDFLAGS_STATIC
1824         ;;
1825 esac
1826
1827 AC_MSG_CHECKING(where we will install curses.h)
1828 test "$with_overwrite" = no && \
1829 test "x$includedir" = 'x${prefix}/include' && \
1830         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1831 AC_MSG_RESULT($includedir)
1832
1833 ### Resolve a conflict between normal and wide-curses by forcing applications
1834 ### that will need libutf8 to add it to their configure script.
1835 if test "$with_overwrite" != no ; then
1836 if test "$NCURSES_LIBUTF8" = 1 ; then
1837         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1838         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1839 fi
1840 fi
1841 WITH_OVERWRITE=$with_overwrite
1842
1843 AC_SUBST(WITH_OVERWRITE)
1844 AC_SUBST(TICS_LIST)
1845 AC_SUBST(TINFO_LIST)
1846 AC_SUBST(SHLIB_LIST)
1847
1848 # used to separate tack out of the tree
1849 NCURSES_TREE=
1850 AC_SUBST(NCURSES_TREE)
1851
1852 ### predefined stuff for the test programs
1853 AC_DEFINE(HAVE_SLK_COLOR)
1854
1855 ### Construct the list of subdirectories for which we'll customize makefiles
1856 ### with the appropriate compile-rules.
1857
1858 CF_SRC_MODULES($modules_to_build)
1859
1860 if test "$cf_with_ada" != "no" && test "$cf_cv_prog_gnat_correct" != "no"; then
1861    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1862    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${DFT_ARG_SUFFIX}-config.1:man/MKada_config.in"
1863 fi
1864
1865 CF_DIRS_TO_MAKE
1866
1867 # symbols that differ when compiling Ada95 by itself.
1868 NCURSES_SHLIB2='sh $(top_srcdir)/misc/shlib'
1869 AC_SUBST(NCURSES_SHLIB2)
1870
1871 # values to use as strings
1872 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR')
1873
1874 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1875
1876 ### Now that we're done running tests, add the compiler-warnings, if any
1877 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1878
1879 ### Define substitutions for header files to avoid name-pollution
1880 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1881 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1882 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1883
1884 ################################################################################
1885 test "$use_database" = yes && \
1886 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1887
1888 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1889 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${DFT_ARG_SUFFIX}${cf_cv_abi_version}-config.1:man/MKncu_config.in"
1890
1891 if test x"$enable_pc_files" = xyes ; then \
1892 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1893 MAKE_PC_FILES=
1894 else
1895 MAKE_PC_FILES="#"
1896 fi
1897 AC_SUBST(MAKE_PC_FILES)
1898 AC_SUBST(cross_compiling)
1899
1900 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
1901 if test -n "$FALLBACK_LIST"
1902 then
1903         if test "$TIC_PATH" = unknown
1904         then
1905                 AC_MSG_WARN(no tic program found for fallbacks)
1906         fi
1907 fi
1908 AC_SUBST(TIC_PATH)
1909
1910 if test "x$cf_with_tests" != xno ; then
1911         MAKE_TESTS=
1912 else
1913         MAKE_TESTS="#"
1914 fi
1915 AC_SUBST(MAKE_TESTS)
1916
1917 ADAHTML_DIR=../../doc/html/ada
1918 AC_SUBST(ADAHTML_DIR)
1919
1920 SUB_SCRIPTS=
1921 case $cf_cv_system_name in #(vi
1922 *mingw32*) #(vi
1923         SUB_SCRIPTS="mk-dlls.sh"
1924         ;;
1925 esac
1926
1927 AC_OUTPUT( \
1928         include/MKterm.h.awk \
1929         include/curses.head:include/curses.h.in \
1930         include/ncurses_dll.h \
1931         include/termcap.h \
1932         include/unctrl.h \
1933         $SUB_SCRIPTS \
1934         $SUB_MAKEFILES \
1935         Makefile,[
1936 if test "x$cf_with_tests" != xno ; then
1937         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LINK"], test)
1938 fi
1939 CF_LIB_RULES($SRC_SUBDIRS)
1940
1941 if test "x$cf_with_ada" != xno ; then
1942 if test -z "$USE_OLD_MAKERULES" ; then
1943         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
1944 fi
1945 fi
1946 ],[
1947 ### Special initialization commands, used to pass information from the
1948 ### configuration-run into config.status
1949
1950 AWK="$AWK"
1951 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1952 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1953 ECHO_LINK="$ECHO_LINK"
1954 LDCONFIG="$LDCONFIG"
1955 LIBTOOL_VERSION="$LIBTOOL_VERSION"
1956 LIB_NAME="$LIB_NAME"
1957 LIB_SUBSETS="$LIB_SUBSETS"
1958 LIB_SUFFIX="$LIB_SUFFIX"
1959 LIB_TRACING="$LIB_TRACING"
1960 LN_S="$LN_S"
1961 MAKE_TERMINFO="$MAKE_TERMINFO"
1962 NCURSES_MAJOR="$NCURSES_MAJOR"
1963 NCURSES_MINOR="$NCURSES_MINOR"
1964 NCURSES_OSPEED="$NCURSES_OSPEED"
1965 NCURSES_PATCH="$NCURSES_PATCH"
1966 SRC_SUBDIRS="$SRC_SUBDIRS"
1967 TERMINFO="$TERMINFO"
1968 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1969 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1970 TICS_NAME="$TICS_NAME"
1971 TIC_PATH="$TIC_PATH"
1972 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1973 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1974 TINFO_NAME="$TINFO_NAME"
1975 TINFO_SUFFIX="$TINFO_SUFFIX"
1976 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
1977 WITH_CURSES_H="$with_curses_h"
1978 WITH_ECHO="$with_echo"
1979 WITH_OVERWRITE="$with_overwrite"
1980 cf_LIST_MODELS="$cf_list_models"
1981 cf_cv_abi_version="$cf_cv_abi_version"
1982 cf_cv_do_relink="$cf_cv_do_relink"
1983 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1984 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1985 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1986 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1987 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1988 cf_cv_rel_version="$cf_cv_rel_version"
1989 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1990 cf_cv_shared_soname='$cf_cv_shared_soname'
1991 cf_cv_shlib_version="$cf_cv_shlib_version"
1992 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1993 cf_cv_system_name="$cf_cv_system_name"
1994 cf_with_ada="$cf_with_ada"
1995 cf_with_cxx_binding="$cf_with_cxx_binding"
1996 cf_with_manpages="$cf_with_manpages"
1997 cf_with_tests="$cf_with_tests"
1998 host="$host"
1999 target="$target"
2000
2001 ],cat)dnl
2002 ${MAKE:-make} preinstall