ncurses 5.9 - patch 20110604
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2010,2011 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: configure.in,v 1.522 2011/04/23 23:48:10 tom Exp $
32 dnl Process this file with autoconf to produce a configure script.
33 dnl
34 dnl See http://invisible-island.net/autoconf/ for additional information.
35 dnl
36 dnl ---------------------------------------------------------------------------
37 AC_PREREQ(2.13.20020210)
38 AC_REVISION($Revision: 1.522 $)
39 AC_INIT(ncurses/base/lib_initscr.c)
40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
41
42 CF_TOP_BUILDDIR
43 CF_SUBST_NCURSES_VERSION
44
45 CF_WITH_REL_VERSION(NCURSES)
46 CF_WITH_ABI_VERSION
47
48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
49 AC_ARG_WITH(system-type,
50 [  --with-system-type=XXX  test: override derived host system-type],
51 [AC_MSG_WARN(overriding system type to $withval)
52  cf_cv_system_name=$withval])
53
54 ###     Save the given $CFLAGS to allow user-override.
55 cf_user_CFLAGS="$CFLAGS"
56
57 ###     Default install-location
58 CF_CFG_DEFAULTS
59
60 ###     Checks for programs.
61 AC_PROG_CC
62 CF_GCC_VERSION
63
64 AC_PROG_CPP
65 AC_PROG_GCC_TRADITIONAL
66 CF_PROG_CC_C_O(CC)
67 AC_ISC_POSIX
68 CF_ANSI_CC_REQD
69 CF_PROG_EXT
70 CF_PROG_LDCONFIG
71
72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
73 dnl                             configure script by not letting us test if C++
74 dnl                             is present, making this option necessary.
75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
76 AC_ARG_WITH(cxx,
77         [  --without-cxx           do not adjust ncurses bool to match C++],
78         [cf_with_cxx=$withval],
79         [cf_with_cxx=yes])
80 AC_MSG_RESULT($cf_with_cxx)
81 if test "X$cf_with_cxx" = Xno ; then
82         CXX=""
83         GXX=""
84 else
85         # with autoconf 2.13, we can change the error to a warning:
86         pushdef([AC_MSG_ERROR],
87                 [AC_MSG_RESULT(no)
88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
90         AC_PROG_CXX
91         popdef([AC_MSG_ERROR])dnl
92         # autoconf 2.5x removed the error - by hardcoding it to g++.
93         if test "$CXX" = "g++" ; then
94                 AC_PATH_PROG(CXX,g++)
95         fi
96         if test "$CXX" = "g++" ; then
97                 AC_MSG_WARN(ignoring hardcoded g++)
98                 cf_with_cxx=no; CXX=""; GXX="";
99         fi
100 fi
101
102 CF_GXX_VERSION
103 case $GXX_VERSION in
104 1*|2.[[0-6]]*)
105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
106         # cf_cxx_library=no
107         AC_MSG_WARN(templates do not work)
108         ;;
109 esac
110
111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
112 AC_ARG_WITH(cxx-binding,
113         [  --without-cxx-binding   do not build C++ binding and demo],
114         [cf_with_cxx_binding=$withval],
115         [cf_with_cxx_binding=$cf_with_cxx])
116 AC_MSG_RESULT($cf_with_cxx_binding)
117
118 AC_MSG_CHECKING(if you want to build with Ada95)
119 AC_ARG_WITH(ada,
120         [  --without-ada           suppress check for Ada95, don't build demo],
121         [cf_with_ada=$withval],
122         [cf_with_ada=yes])
123 AC_MSG_RESULT($cf_with_ada)
124
125 AC_MSG_CHECKING(if you want to install manpages)
126 AC_ARG_WITH(manpages,
127         [  --without-manpages      suppress install of manpages],
128         [cf_with_manpages=$withval],
129         [cf_with_manpages=yes])
130 AC_MSG_RESULT($cf_with_manpages)
131
132 AC_MSG_CHECKING(if you want to build programs such as tic)
133 AC_ARG_WITH(progs,
134         [  --without-progs         suppress build with programs (e.g., tic)],
135         [cf_with_progs=$withval],
136         [cf_with_progs=yes])
137 AC_MSG_RESULT($cf_with_progs)
138
139 AC_MSG_CHECKING(if you want to build test-programs)
140 AC_ARG_WITH(tests,
141         [  --without-tests         suppress build with test-programs],
142         [cf_with_tests=$withval],
143         [cf_with_tests=yes])
144 AC_MSG_RESULT($cf_with_tests)
145
146 AC_MSG_CHECKING(if you wish to install curses.h)
147 AC_ARG_WITH(curses-h,
148         [  --without-curses-h      install curses.h as ncurses.h only],
149         [with_curses_h=$withval],
150         [with_curses_h=yes])
151 AC_MSG_RESULT($with_curses_h)
152
153 modules_to_build="ncurses"
154 if test "X$cf_with_progs" != Xno ; then
155 modules_to_build="$modules_to_build progs tack"
156 fi
157 modules_to_build="$modules_to_build panel menu form"
158
159 AC_ARG_PROGRAM
160
161 CF_PROG_AWK
162 CF_PROG_EGREP
163 CF_PROG_INSTALL
164 CF_PROG_LINT
165 CF_PROG_LN_S
166
167 AC_SYS_LONG_FILE_NAMES
168
169 # if we find pkg-config, check if we should install the ".pc" files.
170 CF_PKG_CONFIG
171
172 if test "$PKG_CONFIG" != no ; then
173         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
174
175         # Leave this as something that can be overridden in the environment.
176         if test -z "$PKG_CONFIG_LIBDIR" ; then
177                 PKG_CONFIG_LIBDIR=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`/lib/pkgconfig
178         fi
179         PKG_CONFIG_LIBDIR=`echo "$PKG_CONFIG_LIBDIR" | sed -e 's/^://' -e 's/:.*//'`
180         if test -n "$PKG_CONFIG_LIBDIR" && test -d "$PKG_CONFIG_LIBDIR" ; then
181                 AC_ARG_ENABLE(pc-files,
182                         [  --enable-pc-files       generate and install .pc files for pkg-config],
183                         [enable_pc_files=$enableval],
184                         [enable_pc_files=no])
185                 AC_MSG_RESULT($enable_pc_files)
186         else
187                 AC_MSG_RESULT(no)
188                 AC_MSG_WARN(did not find library $PKG_CONFIG_LIBDIR)
189                 enable_pc_files=no
190         fi
191 fi
192 AC_SUBST(PKG_CONFIG_LIBDIR)
193
194 AC_MSG_CHECKING(if we should assume mixed-case filenames)
195 AC_ARG_ENABLE(mixed-case,
196         [  --enable-mixed-case     tic should assume mixed-case filenames],
197         [enable_mixedcase=$enableval],
198         [enable_mixedcase=auto])
199 AC_MSG_RESULT($enable_mixedcase)
200 if test "$enable_mixedcase" = "auto" ; then
201     CF_MIXEDCASE_FILENAMES
202 else
203     cf_cv_mixedcase=$enable_mixedcase
204     if test "$enable_mixedcase" = "yes" ; then
205         AC_DEFINE(MIXEDCASE_FILENAMES)
206     fi
207 fi
208
209 # do this after mixed-case option (tags/TAGS is not as important as tic).
210 AC_PROG_MAKE_SET
211 CF_MAKE_TAGS
212 CF_MAKEFLAGS
213
214 dnl These are standard among *NIX systems, but not when cross-compiling
215 AC_CHECK_TOOL(RANLIB, ranlib, ':')
216 AC_CHECK_TOOL(LD, ld, ld)
217 AC_CHECK_TOOL(AR, ar, ar)
218 CF_AR_FLAGS
219
220 dnl Special option for use by system-builders: the install-prefix is used to
221 dnl adjust the location into which the actual install is done, so that an
222 dnl archive can be built without modifying the host system's configuration.
223 AC_MSG_CHECKING(if you have specified an install-prefix)
224 AC_ARG_WITH(install-prefix,
225         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
226         [case "$withval" in #(vi
227         yes|no) #(vi
228                 ;;
229         *)      DESTDIR="$withval"
230                 ;;
231         esac])
232 AC_MSG_RESULT($DESTDIR)
233 AC_SUBST(DESTDIR)
234
235 ###############################################################################
236 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
237 # If we're cross-compiling, allow the user to override the tools and their
238 # options.  The configure script is oriented toward identifying the host
239 # compiler, etc., but we need a build compiler to generate parts of the source.
240 CF_BUILD_CC
241
242 ###############################################################################
243 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
244
245 ### Options to allow the user to specify the set of libraries which are used.
246 ### Use "--without-normal --with-shared" to allow the default model to be
247 ### shared, for example.
248 cf_list_models=""
249 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
250
251 CF_WITH_LIBTOOL
252 if test "$with_libtool" != "no" ; then
253
254 cf_list_models="$cf_list_models libtool"
255
256 else
257
258 AC_MSG_CHECKING(if you want to build shared libraries)
259 AC_ARG_WITH(shared,
260         [  --with-shared           generate shared-libraries],
261         [with_shared=$withval],
262         [with_shared=no])
263 AC_MSG_RESULT($with_shared)
264 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
265
266 AC_MSG_CHECKING(if you want to build static libraries)
267 AC_ARG_WITH(normal,
268         [  --with-normal           generate normal-libraries (default)],
269         [with_normal=$withval],
270         [with_normal=yes])
271 AC_MSG_RESULT($with_normal)
272 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
273
274 AC_MSG_CHECKING(if you want to build debug libraries)
275 AC_ARG_WITH(debug,
276         [  --with-debug            generate debug-libraries (default)],
277         [with_debug=$withval],
278         [with_debug=yes])
279 AC_MSG_RESULT($with_debug)
280 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
281
282 AC_MSG_CHECKING(if you want to build profiling libraries)
283 AC_ARG_WITH(profile,
284         [  --with-profile          generate profile-libraries],
285         [with_profile=$withval],
286         [with_profile=no])
287 AC_MSG_RESULT($with_profile)
288 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
289
290 fi
291
292 ###############################################################################
293
294 AC_MSG_CHECKING(for specified models)
295 test -z "$cf_list_models" && cf_list_models=normal
296 dnl If we use libtool to generate libraries, then it must be the only
297 dnl specified model.
298 test "$with_libtool" != "no" && cf_list_models=libtool
299 AC_MSG_RESULT($cf_list_models)
300
301 ### Use the first model as the default, and save its suffix for use in building
302 ### up test-applications.
303 AC_MSG_CHECKING(for default model)
304 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
305 AC_MSG_RESULT($DFT_LWR_MODEL)
306
307 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
308
309 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
310 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
311
312 TICS_NAME=tic
313 AC_SUBST(TICS_NAME)
314
315 TINFO_NAME=tinfo
316 AC_SUBST(TINFO_NAME)
317
318 LIB_NAME=ncurses
319 AC_SUBST(LIB_NAME)
320
321 LIB_DIR=../lib
322 LIB_2ND=../../lib
323
324 CF_LIB_PREFIX(cf_prefix)
325 LIB_PREFIX=$cf_prefix
326 AC_SUBST(LIB_PREFIX)
327
328 LIB_SUFFIX=
329 AC_SUBST(LIB_SUFFIX)
330
331 ###############################################################################
332
333 AC_MSG_CHECKING(if you want to build a separate terminfo library)
334 AC_ARG_WITH(termlib,
335         [  --with-termlib          generate separate terminfo library],
336         [with_termlib=$withval],
337         [with_termlib=no])
338 AC_MSG_RESULT($with_termlib)
339
340 AC_MSG_CHECKING(if you want to build a separate tic library)
341 AC_ARG_WITH(ticlib,
342         [  --with-ticlib           generate separate tic library],
343         [with_ticlib=$withval],
344         [with_ticlib=no])
345 AC_MSG_RESULT($with_ticlib)
346
347 ### Checks for special libraries, must be done up-front.
348 SHLIB_LIST=""
349 CF_WITH_GPM
350 if test "$with_gpm" != no ; then
351         AC_MSG_CHECKING(if you want to load GPM dynamically)
352         AC_ARG_WITH(dlsym,
353                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
354                 [with_dlsym=$withval],
355                 [with_dlsym=yes])
356         AC_MSG_RESULT($with_dlsym)
357         if test "$with_dlsym" = yes ; then
358                 CF_FUNC_DLSYM
359                 if test "$with_gpm" != yes ; then
360                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
361                         cf_cv_gpm_soname="$with_gpm"
362                 else
363                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
364                 fi
365                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
366                 SHLIB_LIST="-ldl $SHLIB_LIST"
367         else
368                 SHLIB_LIST="-lgpm $SHLIB_LIST"
369                 CF_ADD_LIB(gpm,TEST_LIBS)
370         fi
371         AC_DEFINE(HAVE_LIBGPM)
372         CF_CHECK_GPM_WGETCH
373 fi
374
375 CF_WITH_SYSMOUSE
376
377 dnl Not all ports of gcc support the -g option
378
379 if test X"$CC_G_OPT" = X"" ; then
380         CC_G_OPT='-g'
381         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
382 fi
383 AC_SUBST(CC_G_OPT)
384
385 if test X"$CXX_G_OPT" = X"" ; then
386         CXX_G_OPT='-g'
387         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
388 fi
389 AC_SUBST(CXX_G_OPT)
390
391 AC_MSG_CHECKING(for default loader flags)
392 case $DFT_LWR_MODEL in
393 libtool) LD_MODEL=''   ;;
394 normal)  LD_MODEL=''   ;;
395 debug)   LD_MODEL=$CC_G_OPT ;;
396 profile) LD_MODEL='-pg';;
397 shared)  LD_MODEL=''   ;;
398 esac
399 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
400 AC_MSG_RESULT($LD_MODEL)
401
402 case $DFT_LWR_MODEL in
403 shared)
404 CF_ENABLE_RPATH
405 AC_MSG_CHECKING(if shared libraries should be relinked during install)
406 AC_ARG_ENABLE(relink,
407 [  --disable-relink        relink shared libraries during install],
408 [cf_cv_do_relink=$enableval],
409 [cf_cv_do_relink=yes])
410 AC_MSG_RESULT($cf_cv_do_relink)
411         ;;
412 esac
413
414 CF_SHARED_OPTS
415 if test "$CC_SHARED_OPTS" = "unknown"; then
416         for model in $cf_list_models; do
417                 if test "$model" = "shared"; then
418                         AC_ERROR(Shared libraries are not supported in this version)
419                 fi
420         done
421 fi
422
423 ### If we're building with rpath, try to link non-standard libs that way too.
424 if test "$DFT_LWR_MODEL" = "shared"; then
425         CF_DISABLE_RPATH_HACK
426 fi
427
428 ###############################################################################
429 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
430
431 ###     use option --disable-overwrite to leave out the link to -lcurses
432 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
433 AC_ARG_ENABLE(overwrite,
434         [  --disable-overwrite     leave out the link to -lcurses],
435         [with_overwrite=$enableval],
436         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
437 AC_MSG_RESULT($with_overwrite)
438
439 AC_MSG_CHECKING(if external terminfo-database is used)
440 AC_ARG_ENABLE(database,
441         [  --disable-database      do not use terminfo, only fallbacks/termcap],
442         [use_database=$enableval],
443         [use_database=yes])
444 AC_MSG_RESULT($use_database)
445
446 case $host_os in #(vi
447 os2*) #(vi
448         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
449         ;;
450 *) #(vi
451         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
452         ;;
453 esac
454 AC_SUBST(TERMINFO_SRC)
455
456 CF_PATHSEP
457 if test "$use_database" != no ; then
458         AC_DEFINE(USE_DATABASE)
459
460         AC_MSG_CHECKING(which terminfo source-file will be installed)
461         AC_ARG_WITH(database,
462                 [  --with-database=XXX     specify terminfo source to install],
463                 [TERMINFO_SRC=$withval])
464         AC_MSG_RESULT($TERMINFO_SRC)
465
466         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
467         AC_ARG_WITH(hashed-db,
468                 [  --with-hashed-db        specify hashed-database library],,
469                 [with_hashed_db=no])
470         AC_MSG_RESULT($with_hashed_db)
471 else
472         with_hashed_db=no
473 fi
474
475 AC_MSG_CHECKING(for list of fallback descriptions)
476 AC_ARG_WITH(fallbacks,
477         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
478         [with_fallback=$withval],
479         [with_fallback=])
480 AC_MSG_RESULT($with_fallback)
481 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
482 AC_SUBST(FALLBACK_LIST)
483
484 AC_MSG_CHECKING(if you want modern xterm or antique)
485 AC_ARG_WITH(xterm-new,
486         [  --without-xterm-new     specify if xterm terminfo should be old version],
487         [with_xterm_new=$withval],
488         [with_xterm_new=yes])
489 case $with_xterm_new in
490 no)     with_xterm_new=xterm-old;;
491 *)      with_xterm_new=xterm-new;;
492 esac
493 AC_MSG_RESULT($with_xterm_new)
494 WHICH_XTERM=$with_xterm_new
495 AC_SUBST(WHICH_XTERM)
496
497 MAKE_TERMINFO=
498 if test "$use_database" = no ; then
499         TERMINFO="${datadir}/terminfo"
500         MAKE_TERMINFO="#"
501 else
502
503 AC_MSG_CHECKING(for list of terminfo directories)
504 CF_WITH_PATHLIST(terminfo-dirs,
505         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
506         TERMINFO_DIRS,
507         DATADIR/terminfo,
508         ${datadir}/terminfo)
509 AC_MSG_RESULT($TERMINFO_DIRS)
510 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
511
512 AC_MSG_CHECKING(for default terminfo directory)
513 CF_WITH_PATH(default-terminfo-dir,
514         [  --with-default-terminfo-dir=DIR default terminfo directory],
515         TERMINFO,
516         DATADIR/terminfo,
517         ${datadir}/terminfo)
518 AC_MSG_RESULT($TERMINFO)
519 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
520
521 fi
522
523 AC_SUBST(TERMINFO)
524 AC_SUBST(MAKE_TERMINFO)
525
526 ###     use option --disable-big-core to make tic run on small machines
527 ###     We need 4Mb, check if we can allocate 50% more than that.
528 AC_MSG_CHECKING(if big-core option selected)
529 AC_ARG_ENABLE(big-core,
530         [  --disable-big-core      assume machine has little memory],
531         [with_big_core=$enableval],
532         [AC_TRY_RUN([
533 #include <stdlib.h>
534 #include <string.h>
535 int main() {
536         unsigned long n = 6000000L;
537         char *s = malloc(n);
538         if (s != 0)
539                 s[0] = s[n-1] = 0;
540         ${cf_cv_main_return:-return}(s == 0);
541 }],
542         [with_big_core=yes],
543         [with_big_core=no],
544         [with_big_core=no])])
545 AC_MSG_RESULT($with_big_core)
546 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
547
548 ### ISO C only guarantees 512-char strings, we have tables which load faster
549 ### when constructed using "big" strings.  More than the C compiler, the awk
550 ### program is a limit on most vendor UNIX systems.  Check that we can build.
551 AC_MSG_CHECKING(if big-strings option selected)
552 AC_ARG_ENABLE(big-strings,
553         [  --disable-big-strings   assume compiler has only standard-size strings],
554         [with_big_strings=$enableval],
555         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
556 AC_MSG_RESULT($with_big_strings)
557
558 USE_BIG_STRINGS=0
559 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
560 AC_SUBST(USE_BIG_STRINGS)
561
562 ###     use option --enable-termcap to compile in the termcap fallback support
563 AC_MSG_CHECKING(if you want termcap-fallback support)
564 AC_ARG_ENABLE(termcap,
565         [  --enable-termcap        compile in termcap fallback support],
566         [with_termcap=$enableval],
567         [with_termcap=no])
568 AC_MSG_RESULT($with_termcap)
569
570 if test "$with_termcap" != "yes" ; then
571         if test "$use_database" = no ; then
572                 if test -z "$with_fallback" ; then
573                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
574                 fi
575         fi
576         AC_DEFINE(PURE_TERMINFO)
577 else
578
579 if test "$with_ticlib" != no ; then
580         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
581 fi
582
583 AC_DEFINE(USE_TERMCAP)
584 AC_MSG_CHECKING(for list of termcap files)
585 CF_WITH_PATHLIST(termpath,
586         [  --with-termpath=XXX     specify list of termcap files],
587         TERMPATH,
588         /etc/termcap:/usr/share/misc/termcap)
589 AC_MSG_RESULT($TERMPATH)
590 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
591
592 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
593 AC_MSG_CHECKING(if fast termcap-loader is needed)
594 AC_ARG_ENABLE(getcap,
595         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
596         [with_getcap=$enableval],
597         [with_getcap=no])
598 AC_MSG_RESULT($with_getcap)
599 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
600
601 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
602 AC_ARG_ENABLE(getcap-cache,
603         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
604         [with_getcap_cache=$enableval],
605         [with_getcap_cache=no])
606 AC_MSG_RESULT($with_getcap_cache)
607 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
608
609 fi
610
611 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
612 AC_MSG_CHECKING(if ~/.terminfo is wanted)
613 AC_ARG_ENABLE(home-terminfo,
614         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
615         [with_home_terminfo=$enableval],
616         [with_home_terminfo=yes])
617 AC_MSG_RESULT($with_home_terminfo)
618 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
619
620 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
621 AC_ARG_ENABLE(root-environ,
622         [  --disable-root-environ  restrict environment when running as root],
623         [with_root_environ=$enableval],
624         [with_root_environ=yes])
625 AC_MSG_RESULT($with_root_environ)
626 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
627
628 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
629 ###   to reduce storage requirements for the terminfo database.
630 CF_LINK_FUNCS
631
632 with_links=no
633 with_symlinks=no
634
635 # soft links (symbolic links) are useful for some systems where hard links do
636 # not work, or to make it simpler to copy terminfo trees around.
637 if test "$ac_cv_func_symlink" = yes ; then
638     AC_MSG_CHECKING(if tic should use symbolic links)
639     AC_ARG_ENABLE(symlinks,
640         [  --enable-symlinks       make tic use symbolic links not hard links],
641         [with_symlinks=$enableval],
642         [with_symlinks=no])
643     AC_MSG_RESULT($with_symlinks)
644 fi
645
646 # If we have hard links and did not choose to use soft links instead, there is
647 # no reason to make this choice optional - use the hard links.
648 if test "$with_symlinks" = no ; then
649     AC_MSG_CHECKING(if tic should use hard links)
650     if test "$ac_cv_func_link" = yes ; then
651         with_links=yes
652     else
653         with_links=no
654     fi
655     AC_MSG_RESULT($with_links)
656 fi
657
658 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
659 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
660
661 ###   use option --enable-broken-linker to force on use of broken-linker support
662 AC_MSG_CHECKING(if you want broken-linker support code)
663 AC_ARG_ENABLE(broken_linker,
664         [  --enable-broken_linker  compile with broken-linker support code],
665         [with_broken_linker=$enableval],
666         [with_broken_linker=${BROKEN_LINKER:-no}])
667 AC_MSG_RESULT($with_broken_linker)
668
669 BROKEN_LINKER=0
670 if test "$with_broken_linker" = yes ; then
671         AC_DEFINE(BROKEN_LINKER)
672         BROKEN_LINKER=1
673 elif test "$DFT_LWR_MODEL" = shared ; then
674         case $cf_cv_system_name in #(vi
675         cygwin*)
676                 AC_DEFINE(BROKEN_LINKER)
677                 BROKEN_LINKER=1
678                 CF_VERBOSE(cygwin linker is broken anyway)
679                 ;;
680         esac
681 fi
682 AC_SUBST(BROKEN_LINKER)
683
684 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
685 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
686 AC_ARG_ENABLE(bsdpad,
687         [  --enable-bsdpad         recognize BSD-style prefix padding],
688         [with_bsdpad=$enableval],
689         [with_bsdpad=no])
690 AC_MSG_RESULT($with_bsdpad)
691 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
692
693 ###   use option --enable-widec to turn on use of wide-character support
694 NCURSES_CH_T=chtype
695 NCURSES_LIBUTF8=0
696
697 NEED_WCHAR_H=0
698 NCURSES_MBSTATE_T=0
699 NCURSES_WCHAR_T=0
700 NCURSES_WINT_T=0
701
702 # Check to define _XOPEN_SOURCE "automatically"
703 CF_XOPEN_SOURCE(500)
704
705 # Work around breakage on OS X
706 CF_SIGWINCH
707
708 # Checks for CODESET support.
709 AM_LANGINFO_CODESET
710
711 # use these variables to work around a defect in gcc's fixincludes.
712 NCURSES_OK_WCHAR_T=
713 NCURSES_OK_WINT_T=
714
715 AC_MSG_CHECKING(if you want wide-character code)
716 AC_ARG_ENABLE(widec,
717         [  --enable-widec          compile with wide-char/UTF-8 code],
718         [with_widec=$enableval],
719         [with_widec=no])
720 AC_MSG_RESULT($with_widec)
721 if test "$with_widec" = yes ; then
722         LIB_SUFFIX="w${LIB_SUFFIX}"
723         AC_DEFINE(USE_WIDEC_SUPPORT)
724
725         case "$CFLAGS $CPPFLAGS" in #(vi
726         *-D_XOPEN_SOURCE=500) #(vi
727                 ;;
728         *)
729                 CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
730                 ;;
731         esac
732
733         # with_overwrite=no
734         NCURSES_CH_T=cchar_t
735         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
736         if test "$ac_cv_func_putwc" != yes ; then
737                 CF_UTF8_LIB
738                 if test "$cf_cv_utf8_lib" != no ; then
739                         NCURSES_LIBUTF8=1
740                 fi
741         fi
742         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
743         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
744         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
745
746         if test "$NCURSES_MBSTATE_T" != 0; then
747                 AC_DEFINE(NEED_MBSTATE_T_DEF)
748         fi
749 fi
750 AC_SUBST(NCURSES_CH_T)
751 AC_SUBST(NCURSES_LIBUTF8)
752
753 AC_SUBST(NEED_WCHAR_H)
754 AC_SUBST(NCURSES_MBSTATE_T)
755 AC_SUBST(NCURSES_WCHAR_T)
756 AC_SUBST(NCURSES_WINT_T)
757
758 AC_SUBST(NCURSES_OK_WCHAR_T)
759 AC_SUBST(NCURSES_OK_WINT_T)
760
761 ###   use option --disable-lp64 to allow long chtype
762 case $cf_cv_abi_version in
763 [[345]]*)
764         default_with_lp64=no
765         ;;
766 *)
767         default_with_lp64=yes
768         ;;
769 esac
770
771 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
772 AC_ARG_ENABLE(lp64,
773         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
774         [with_lp64=$enableval],
775         [with_lp64=$default_with_lp64])
776 AC_MSG_RESULT($with_lp64)
777
778 if test "$with_lp64" = yes ; then
779         cf_cv_enable_lp64=1
780 else
781         cf_cv_enable_lp64=0
782 fi
783 AC_SUBST(cf_cv_enable_lp64)
784
785 CF_LARGEFILE
786
787 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
788 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
789 AC_ARG_ENABLE(tparm-varargs,
790         [  --disable-tparm-varargs compile tparm() without varargs interface],
791         [with_tparm_varargs=$enableval],
792         [with_tparm_varargs=yes])
793 AC_MSG_RESULT($with_tparm_varargs)
794 NCURSES_TPARM_VARARGS=0
795 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
796 AC_SUBST(NCURSES_TPARM_VARARGS)
797
798 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
799 if test "$with_ticlib" != no ; then
800 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
801 AC_ARG_ENABLE(tic-depends,
802         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
803         [with_tic_depends=$enableval],
804         [with_tic_depends=yes])
805 AC_MSG_RESULT($with_tic_depends)
806 else
807         with_tic_depends=no
808 fi
809
810 ###   use option --with-bool to override bool's type
811 AC_MSG_CHECKING(for type of bool)
812 AC_ARG_WITH(bool,
813         [  --with-bool=TYPE        override fallback type of bool variable],
814         [NCURSES_BOOL="$withval"],
815         [NCURSES_BOOL=auto])
816 AC_MSG_RESULT($NCURSES_BOOL)
817 AC_SUBST(NCURSES_BOOL)
818
819 AC_MSG_CHECKING(for alternate terminal capabilities file)
820 AC_ARG_WITH(caps,
821         [  --with-caps=alt         compile with alternate Caps file],
822         [TERMINFO_CAPS=Caps.$withval],
823         [TERMINFO_CAPS=Caps])
824 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
825 AC_MSG_RESULT($TERMINFO_CAPS)
826 AC_SUBST(TERMINFO_CAPS)
827
828 ###   use option --with-chtype to override chtype's type
829 AC_MSG_CHECKING(for type of chtype)
830 AC_ARG_WITH(chtype,
831         [  --with-chtype=TYPE      override type of chtype],
832         [NCURSES_CHTYPE="$withval"],
833         [NCURSES_CHTYPE=auto])
834 AC_MSG_RESULT($NCURSES_CHTYPE)
835
836 ###   use option --with-ospeed to override ospeed's type
837 AC_MSG_CHECKING(for type of ospeed)
838 AC_ARG_WITH(ospeed,
839         [  --with-ospeed=TYPE      override type of ospeed variable],
840         [NCURSES_OSPEED="$withval"],
841         [NCURSES_OSPEED=short])
842 AC_MSG_RESULT($NCURSES_OSPEED)
843 AC_SUBST(NCURSES_OSPEED)
844
845 ###   use option --with-mmask-t to override mmask_t's type
846 AC_MSG_CHECKING(for type of mmask_t)
847 AC_ARG_WITH(mmask-t,
848         [  --with-mmask-t=TYPE     override type of mmask_t],
849         [NCURSES_MMASK_T="$withval"],
850         [NCURSES_MMASK_T=auto])
851 AC_MSG_RESULT($NCURSES_MMASK_T)
852
853 ###   use option --with-ccharw-max to override CCHARW_MAX size
854 AC_MSG_CHECKING(for size CCHARW_MAX)
855 AC_ARG_WITH(ccharw-max,
856         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
857         [NCURSES_CCHARW_MAX="$withval"],
858         [NCURSES_CCHARW_MAX=5])
859 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
860 AC_SUBST(NCURSES_CCHARW_MAX)
861
862 ### Enable compiling-in rcs id's
863 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
864 AC_ARG_WITH(rcs-ids,
865         [  --with-rcs-ids          compile-in RCS identifiers],
866         [with_rcs_ids=$withval],
867         [with_rcs_ids=no])
868 AC_MSG_RESULT($with_rcs_ids)
869 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
870
871 ###############################################################################
872 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
873
874 ###############################################################################
875 CF_HELP_MESSAGE(Extensions:)
876
877 ### Note that some functions (such as const) are normally disabled anyway.
878 AC_MSG_CHECKING(if you want to build with function extensions)
879 AC_ARG_ENABLE(ext-funcs,
880         [  --disable-ext-funcs     disable function-extensions],
881         [with_ext_funcs=$enableval],
882         [with_ext_funcs=yes])
883 AC_MSG_RESULT($with_ext_funcs)
884 if test "$with_ext_funcs" = yes ; then
885         NCURSES_EXT_FUNCS=1
886         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS)
887         AC_DEFINE(HAVE_CURSES_VERSION)
888         AC_DEFINE(HAVE_HAS_KEY)
889         AC_DEFINE(HAVE_RESIZETERM)
890         AC_DEFINE(HAVE_RESIZE_TERM)
891         AC_DEFINE(HAVE_TERM_ENTRY_H)
892         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
893         AC_DEFINE(HAVE_USE_SCREEN)
894         AC_DEFINE(HAVE_USE_WINDOW)
895         AC_DEFINE(HAVE_WRESIZE)
896         AC_DEFINE(NCURSES_EXT_FUNCS)
897         GENERATED_EXT_FUNCS=generated
898 else
899         NCURSES_EXT_FUNCS=0
900         GENERATED_EXT_FUNCS=
901 fi
902 AC_SUBST(NCURSES_EXT_FUNCS)
903 AC_SUBST(GENERATED_EXT_FUNCS)
904
905 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
906 AC_ARG_ENABLE(sp-funcs,
907         [  --enable-sp-funcs       enable experimental SCREEN-extensions],
908         [with_sp_funcs=$enableval],
909         [with_sp_funcs=no])
910 AC_MSG_RESULT($with_sp_funcs)
911 if test "$with_sp_funcs" = yes ; then
912         NCURSES_SP_FUNCS=1
913         AC_DEFINE(NCURSES_SP_FUNCS)
914         GENERATED_SP_FUNCS=generated
915 else
916         NCURSES_SP_FUNCS=0
917         GENERATED_SP_FUNCS=
918 fi
919 AC_SUBST(NCURSES_SP_FUNCS)
920 AC_SUBST(GENERATED_SP_FUNCS)
921
922 AC_MSG_CHECKING(if you want to build with experimental terminal-driver)
923 AC_ARG_ENABLE(term-driver,
924         [  --enable-term-driver    enable experimental terminal-driver],
925         [with_term_driver=$enableval],
926         [with_term_driver=no])
927 AC_MSG_RESULT($with_term_driver)
928 if test "$with_term_driver" = yes ; then
929         AC_DEFINE(USE_TERM_DRIVER)
930         if test "$with_sp_funcs" != yes ; then
931                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
932         fi
933 fi
934
935 ###   use option --enable-const to turn on use of const beyond that in XSI.
936 AC_MSG_CHECKING(for extended use of const keyword)
937 AC_ARG_ENABLE(const,
938         [  --enable-const          compile with extra/non-standard const],
939         [with_ext_const=$enableval],
940         [with_ext_const=no])
941 AC_MSG_RESULT($with_ext_const)
942 NCURSES_CONST='/*nothing*/'
943 if test "$with_ext_const" = yes ; then
944         NCURSES_CONST=const
945 fi
946 AC_SUBST(NCURSES_CONST)
947
948 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
949 AC_MSG_CHECKING(if you want to use extended colors)
950 AC_ARG_ENABLE(ext-colors,
951         [  --enable-ext-colors     compile for 256-color support],
952         [with_ext_colors=$enableval],
953         [with_ext_colors=no])
954 AC_MSG_RESULT($with_ext_colors)
955 NCURSES_EXT_COLORS=0
956 if test "$with_ext_colors" = yes ; then
957         if test "$with_widec" != yes ; then
958                 AC_MSG_ERROR(This option applies only to wide-character library)
959         else
960                 # cannot be ABI 5 since it changes sizeof(cchar_t)
961                 CF_NCURSES_ABI_6
962         fi
963         NCURSES_EXT_COLORS=1
964         AC_DEFINE(NCURSES_EXT_COLORS)
965 fi
966 AC_SUBST(NCURSES_EXT_COLORS)
967
968 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
969 AC_MSG_CHECKING(if you want to use extended mouse encoding)
970 AC_ARG_ENABLE(ext-mouse,
971         [  --enable-ext-mouse      compile for extended mouse-encoding],
972         [with_ext_mouse=$enableval],
973         [with_ext_mouse=no])
974 AC_MSG_RESULT($with_ext_mouse)
975 NCURSES_MOUSE_VERSION=1
976 if test "$with_ext_mouse" = yes ; then
977         NCURSES_MOUSE_VERSION=2
978         CF_NCURSES_ABI_6
979 fi
980 AC_SUBST(NCURSES_MOUSE_VERSION)
981
982 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
983 AC_ARG_ENABLE(no-padding,
984         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
985         [with_no_padding=$enableval],
986         [with_no_padding=$with_ext_funcs])
987 AC_MSG_RESULT($with_no_padding)
988 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
989
990 AC_CHECK_SIZEOF([signed char], 0)
991 if test "$ac_cv_sizeof_signed_char" = 1 ; then
992         NCURSES_SBOOL="signed char"
993 else
994         NCURSES_SBOOL="char"
995 fi
996 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
997 AC_ARG_ENABLE(signed-char,
998         [  --enable-signed-char    compile using signed Boolean's in term.h],
999         [with_signed_char=$enableval],
1000         [with_signed_char=no])
1001 AC_MSG_RESULT($with_signed_char)
1002 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
1003 AC_SUBST(NCURSES_SBOOL)
1004
1005 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1006 AC_MSG_CHECKING(if you want SIGWINCH handler)
1007 AC_ARG_ENABLE(sigwinch,
1008         [  --enable-sigwinch       compile with SIGWINCH handler],
1009         [with_sigwinch=$enableval],
1010         [with_sigwinch=$with_ext_funcs])
1011 AC_MSG_RESULT($with_sigwinch)
1012 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
1013
1014 ###   use option --enable-tcap-names to allow user to define new capabilities
1015 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1016 AC_ARG_ENABLE(tcap-names,
1017         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1018         [with_tcap_names=$enableval],
1019         [with_tcap_names=$with_ext_funcs])
1020 AC_MSG_RESULT($with_tcap_names)
1021 NCURSES_XNAMES=0
1022 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
1023 AC_SUBST(NCURSES_XNAMES)
1024
1025 ###############################################################################
1026 # These options are relatively safe to experiment with.
1027 CF_HELP_MESSAGE(Development Code:)
1028 AC_MSG_CHECKING(if you want all development code)
1029 AC_ARG_WITH(develop,
1030         [  --without-develop       disable development options],
1031         [with_develop=$withval],
1032         [with_develop=no])
1033 AC_MSG_RESULT($with_develop)
1034
1035 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1036 AC_MSG_CHECKING(if you want hard-tabs code)
1037 AC_ARG_ENABLE(hard-tabs,
1038         [  --enable-hard-tabs      compile with hard-tabs code],,
1039         [enable_hard_tabs=$with_develop])
1040 AC_MSG_RESULT($enable_hard_tabs)
1041 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
1042
1043 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1044 AC_MSG_CHECKING(if you want limited support for xmc)
1045 AC_ARG_ENABLE(xmc-glitch,
1046         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1047         [enable_xmc_glitch=$with_develop])
1048 AC_MSG_RESULT($enable_xmc_glitch)
1049 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
1050
1051 ###############################################################################
1052 # These are just experimental, probably should not be in a package:
1053 CF_HELP_MESSAGE(Experimental Code:)
1054
1055 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1056 AC_ARG_ENABLE(assumed-color,
1057         [  --disable-assumed-color do not assume anything about default-colors],
1058         [with_assumed_color=$enableval],
1059         [with_assumed_color=yes])
1060 AC_MSG_RESULT($with_assumed_color)
1061 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
1062
1063 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1064 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1065 AC_ARG_ENABLE(hashmap,
1066         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1067         [with_hashmap=$enableval],
1068         [with_hashmap=yes])
1069 AC_MSG_RESULT($with_hashmap)
1070 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
1071
1072 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1073 AC_MSG_CHECKING(if you want colorfgbg code)
1074 AC_ARG_ENABLE(colorfgbg,
1075         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1076         [with_colorfgbg=$enableval],
1077         [with_colorfgbg=no])
1078 AC_MSG_RESULT($with_colorfgbg)
1079 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
1080
1081 ###   use option --enable-interop to turn on use of bindings used for interop
1082 AC_MSG_CHECKING(if you want interop bindings)
1083 AC_ARG_ENABLE(interop,
1084         [  --enable-interop        compile-in experimental interop bindings],
1085         [with_exp_interop=$enableval],
1086         [with_exp_interop=no])
1087 AC_MSG_RESULT($with_exp_interop)
1088
1089 NCURSES_INTEROP_FUNCS=0
1090 test "$with_exp_interop" = yes && NCURSES_INTEROP_FUNCS=1
1091 AC_SUBST(NCURSES_INTEROP_FUNCS)
1092
1093 # This is still experimental (20080329), but should ultimately be moved to
1094 # the script-block --with-normal, etc.
1095 CF_WITH_PTHREAD
1096
1097 if test "x$with_pthread" != xno; then
1098         AC_CHECK_FUNC(pthread_kill,[
1099                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1100                 AC_ARG_ENABLE(pthreads-eintr,
1101                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1102                         [use_pthreads_eintr=$enableval],
1103                         [use_pthreads_eintr=no])
1104                 AC_MSG_RESULT($use_pthreads_eintr)
1105                 if test $use_pthreads_eintr = yes ; then
1106                         AC_DEFINE(USE_PTHREADS_EINTR)
1107                 fi])
1108
1109         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1110         AC_ARG_ENABLE(weak-symbols,
1111                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1112                 [use_weak_symbols=$enableval],
1113                 [use_weak_symbols=no])
1114         AC_MSG_RESULT($use_weak_symbols)
1115         if test "$use_weak_symbols" = yes ; then
1116                 CF_WEAK_SYMBOLS
1117         else
1118                 cf_cv_weak_symbols=no
1119         fi
1120
1121         if test $cf_cv_weak_symbols = yes ; then
1122                 AC_DEFINE(USE_WEAK_SYMBOLS)
1123         fi
1124 fi
1125
1126 PTHREAD=
1127 if test "$with_pthread" = "yes" ; then
1128     AC_DEFINE(USE_PTHREADS)
1129     enable_reentrant=yes
1130     if test $cf_cv_weak_symbols = yes ; then
1131         PTHREAD=-lpthread
1132     fi
1133 fi
1134 AC_SUBST(PTHREAD)
1135
1136 # Reentrant code has to be opaque; there's little advantage to making ncurses
1137 # opaque outside of that, so there is no --enable-opaque option.  We can use
1138 # this option without --with-pthreads, but this will be always set for
1139 # pthreads.
1140 AC_MSG_CHECKING(if you want experimental reentrant code)
1141 AC_ARG_ENABLE(reentrant,
1142         [  --enable-reentrant      compile with experimental reentrant code],
1143         [with_reentrant=$enableval],
1144         [with_reentrant=no])
1145 AC_MSG_RESULT($with_reentrant)
1146 if test "$with_reentrant" = yes ; then
1147         cf_cv_enable_reentrant=1
1148         cf_cv_enable_opaque="NCURSES_INTERNALS"
1149         NCURSES_OPAQUE=1
1150         NCURSES_SIZE_T=int
1151         if test $cf_cv_weak_symbols = yes ; then
1152                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1153                 CF_ADD_LIB(pthread,TEST_LIBS)
1154                 CF_ADD_LIB(pthread,TEST_LIBS2)
1155         else
1156                 LIB_SUFFIX="t${LIB_SUFFIX}"
1157         fi
1158         AC_DEFINE(USE_REENTRANT)
1159         CF_NCURSES_ABI_6
1160 else
1161         cf_cv_enable_reentrant=0
1162         cf_cv_enable_opaque="NCURSES_OPAQUE"
1163         NCURSES_OPAQUE=0
1164         NCURSES_SIZE_T=short
1165 fi
1166 AC_SUBST(cf_cv_enable_reentrant)
1167 AC_SUBST(cf_cv_enable_opaque)
1168 AC_SUBST(NCURSES_OPAQUE)
1169 AC_SUBST(NCURSES_SIZE_T)
1170
1171 ### Allow using a different wrap-prefix
1172 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1173         AC_MSG_CHECKING(for prefix used to wrap public variables)
1174         AC_ARG_WITH(wrap-prefix,
1175                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1176                 [NCURSES_WRAP_PREFIX=$withval],
1177                 [NCURSES_WRAP_PREFIX=_nc_])
1178         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1179 else
1180         NCURSES_WRAP_PREFIX=_nc_
1181 fi
1182 AC_SUBST(NCURSES_WRAP_PREFIX)
1183 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX")
1184
1185 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1186 AC_ARG_ENABLE(safe-sprintf,
1187         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1188         [with_safe_sprintf=$enableval],
1189         [with_safe_sprintf=no])
1190 AC_MSG_RESULT($with_safe_sprintf)
1191 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1192
1193 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1194 # when hashmap is used scroll hints are useless
1195 if test "$with_hashmap" = no ; then
1196 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1197 AC_ARG_ENABLE(scroll-hints,
1198         [  --disable-scroll-hints  compile without scroll-hints code],
1199         [with_scroll_hints=$enableval],
1200         [with_scroll_hints=yes])
1201 AC_MSG_RESULT($with_scroll_hints)
1202 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1203 fi
1204
1205 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1206 AC_ARG_ENABLE(wgetch-events,
1207         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1208         [with_wgetch_events=$enableval],
1209         [with_wgetch_events=no])
1210 AC_MSG_RESULT($with_wgetch_events)
1211 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1212
1213 ###############################################################################
1214 CF_HELP_MESSAGE(Testing/development Options:)
1215
1216 ###     use option --disable-echo to suppress full display compiling commands
1217 AC_MSG_CHECKING(if you want to display full commands during build)
1218 AC_ARG_ENABLE(echo,
1219         [  --enable-echo           build: display "compiling" commands (default)],
1220         [with_echo=$enableval],
1221         [with_echo=yes])
1222 if test "$with_echo" = yes; then
1223         ECHO_LINK=
1224 else
1225         ECHO_LINK='@ echo linking $@ ... ;'
1226         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1227         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1228 fi
1229 AC_MSG_RESULT($with_echo)
1230 AC_SUBST(ECHO_LINK)
1231
1232 ###     use option --enable-warnings to turn on all gcc warnings
1233 AC_MSG_CHECKING(if you want to see compiler warnings)
1234 AC_ARG_ENABLE(warnings,
1235         [  --enable-warnings       build: turn on GCC compiler warnings],
1236         [with_warnings=$enableval])
1237 AC_MSG_RESULT($with_warnings)
1238
1239 if test "x$with_warnings" = "xyes"; then
1240         CF_ADD_ADAFLAGS(-gnatg)
1241         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1242         if test "$cf_with_cxx" = yes ; then
1243                 CF_GXX_WARNINGS(Wno-unused)
1244         fi
1245 fi
1246 CF_GCC_ATTRIBUTES
1247
1248 ###     use option --enable-assertions to turn on generation of assertion code
1249 AC_MSG_CHECKING(if you want to enable runtime assertions)
1250 AC_ARG_ENABLE(assertions,
1251         [  --enable-assertions     test: turn on generation of assertion code],
1252         [with_assertions=$enableval],
1253         [with_assertions=no])
1254 AC_MSG_RESULT($with_assertions)
1255 if test -n "$GCC"
1256 then
1257         if test "$with_assertions" = no
1258         then
1259                 AC_DEFINE(NDEBUG)
1260                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1261         else
1262                 CF_ADD_ADAFLAGS(-gnata)
1263         fi
1264 fi
1265
1266 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1267 CF_DISABLE_LEAKS
1268 AC_DEFINE(HAVE_NC_ALLOC_H)
1269
1270 ###     use option --enable-expanded to generate certain macros as functions
1271 AC_ARG_ENABLE(expanded,
1272         [  --enable-expanded       test: generate functions for certain macros],
1273         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1274
1275 ###     use option --disable-macros to suppress macros in favor of functions
1276 AC_ARG_ENABLE(macros,
1277         [  --disable-macros        test: use functions rather than macros],
1278         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1279
1280 # Normally we only add trace() to the debug-library.  Allow this to be
1281 # extended to all models of the ncurses library:
1282 cf_all_traces=no
1283 case "$CFLAGS $CPPFLAGS" in
1284 *-DTRACE*)
1285         cf_all_traces=yes
1286         ;;
1287 esac
1288
1289 AC_MSG_CHECKING(whether to add trace feature to all models)
1290 AC_ARG_WITH(trace,
1291 [  --with-trace            test: add trace() function to all models of ncurses],
1292 [cf_with_trace=$withval],
1293 [cf_with_trace=$cf_all_traces])
1294 AC_MSG_RESULT($cf_with_trace)
1295
1296 if test "$cf_with_trace" = yes ; then
1297         LIB_TRACING=all
1298         ADA_TRACE=TRUE
1299         CF_ADD_CFLAGS(-DTRACE)
1300 else
1301         LIB_TRACING=DEBUG
1302         ADA_TRACE=FALSE
1303 fi
1304
1305 AC_SUBST(ADA_TRACE)
1306
1307 ###     Checks for libraries.
1308 case $cf_cv_system_name in #(vi
1309 *mingw32*) #(vi
1310         ;;
1311 *)
1312 AC_CHECK_FUNC(gettimeofday,
1313         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1314
1315 AC_CHECK_LIB(bsd, gettimeofday,
1316         AC_DEFINE(HAVE_GETTIMEOFDAY)
1317         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1318         ;;
1319 esac
1320
1321 CF_MATH_LIB(MATH_LIB,sin(x))
1322 AC_SUBST(MATH_LIB)
1323
1324 ###     Checks for header files.
1325 AC_STDC_HEADERS
1326 AC_HEADER_DIRENT
1327 AC_HEADER_TIME
1328 CF_REGEX
1329
1330 dnl These are some other potentially nonportable headers.
1331 AC_CHECK_HEADERS( \
1332 fcntl.h \
1333 getopt.h \
1334 limits.h \
1335 locale.h \
1336 math.h \
1337 poll.h \
1338 sys/bsdtypes.h \
1339 sys/ioctl.h \
1340 sys/param.h \
1341 sys/poll.h \
1342 sys/select.h \
1343 sys/time.h \
1344 sys/times.h \
1345 ttyent.h \
1346 unistd.h \
1347 wctype.h \
1348 )
1349
1350 CF_GETOPT_HEADER
1351
1352 # check for ISC (this may also define _POSIX_SOURCE)
1353 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1354 if test "$ISC" = yes ; then
1355         AC_CHECK_LIB(cposix,main)
1356         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1357 fi
1358
1359 CF_SYS_TIME_SELECT
1360
1361 ###     checks for compiler characteristics
1362 AC_LANG_C
1363 AC_C_CONST
1364 CF_C_INLINE(NCURSES_INLINE,1200)
1365 CF_SIG_ATOMIC_T
1366
1367 if test $NCURSES_CHTYPE = auto ; then
1368         CF_TYPEOF_CHTYPE
1369 else
1370         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1371 fi
1372 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1373 AC_SUBST(cf_cv_typeof_chtype)
1374
1375 CF_UNSIGNED_LITERALS
1376 cf_cv_1UL="1"
1377 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1378 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1379 AC_SUBST(cf_cv_1UL)
1380
1381 if test $NCURSES_MMASK_T = auto ; then
1382         cf_cv_typeof_mmask_t=long
1383 else
1384         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1385 fi
1386 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1387 AC_SUBST(cf_cv_typeof_mmask_t)
1388
1389 ###     Checks for external-data
1390 CF_ERRNO
1391 CF_LINK_DATAONLY
1392
1393 ###     Checks for library functions.
1394 AC_CHECK_FUNCS( \
1395 getcwd \
1396 getegid \
1397 geteuid \
1398 getttynam \
1399 issetugid \
1400 poll \
1401 remove \
1402 select \
1403 setbuf \
1404 setbuffer \
1405 setvbuf \
1406 sigaction \
1407 sigvec \
1408 strdup \
1409 strstr \
1410 tcgetpgrp \
1411 times \
1412 vsnprintf \
1413 )
1414 if test "$with_getcap" = "yes" ; then
1415         CF_CGETENT
1416 fi
1417
1418 CF_ISASCII
1419 CF_STRUCT_SIGACTION
1420 CF_FUNC_NANOSLEEP
1421 CF_FUNC_TERMIOS
1422 CF_FUNC_VSSCANF
1423 CF_MKSTEMP
1424
1425 # setup for prototype of fallback for vsscanf()
1426 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1427
1428 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1429 if test "$cross_compiling" = yes ; then
1430         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1431 else
1432         AC_FUNC_SETVBUF_REVERSED
1433 fi
1434 AC_TYPE_SIGNAL
1435 CF_TYPE_SIGACTION
1436 CF_SIZECHANGE
1437 CF_FUNC_MEMMOVE
1438 CF_FUNC_POLL
1439 CF_VA_COPY
1440 AC_FUNC_VFORK
1441
1442 # special check for test/ditto.c
1443 CF_FUNC_OPENPTY
1444 if test "$cf_cv_func_openpty" != no ; then
1445     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1446     AC_DEFINE(USE_XTERM_PTY)
1447     if test "$cf_cv_lib_util" = yes ; then
1448         CF_ADD_LIB(util,TEST_LIBS)
1449     fi
1450 fi
1451 AC_SUBST(TEST_LIBS)
1452 AC_SUBST(TEST_LIBS2)
1453
1454 if test "$with_hashed_db" != no ; then
1455         AC_DEFINE(USE_HASHED_DB)
1456         CF_HASHED_DB($with_hashed_db)
1457 fi
1458
1459 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1460 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1461         CF_STRIP_G_OPT(CFLAGS)
1462         CF_STRIP_G_OPT(CXXFLAGS)
1463 fi
1464
1465 # Just in case, check if the C compiler has a bool type.
1466 CF_BOOL_DECL(cf_cv_cc_bool_type)
1467
1468 # Check for C++ compiler characteristics (and ensure that it's there!)
1469 if test -n "$CXX" ; then
1470         AC_LANG_CPLUSPLUS
1471         CF_STDCPP_LIBRARY
1472         CF_PROG_CC_C_O(CXX)
1473
1474         case $GXX_VERSION in
1475         1*|2.[0-6]*)
1476                 cf_cxx_library=yes
1477                 ;;
1478         *-2.7*|2.7*)
1479                 CF_GPP_LIBRARY
1480                 ;;
1481         *)
1482                 cf_cxx_library=no
1483                 ;;
1484         esac
1485
1486         AC_CHECK_HEADERS(iostream typeinfo)
1487
1488     if test x"$ac_cv_header_iostream" = xyes ; then
1489         AC_MSG_CHECKING(if iostream uses std-namespace)
1490         AC_TRY_COMPILE([
1491 #include <iostream>
1492 using std::endl;
1493 using std::cerr;],[
1494 cerr << "testing" << endl;
1495 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1496         AC_MSG_RESULT($cf_iostream_namespace)
1497         if test "$cf_iostream_namespace" = yes ; then
1498             AC_DEFINE(IOSTREAM_NAMESPACE)
1499         fi
1500     fi
1501
1502         CF_BOOL_DECL
1503         CF_BOOL_SIZE
1504         CF_ETIP_DEFINES
1505         CF_CPP_PARAM_INIT
1506         CF_CPP_STATIC_CAST
1507
1508         CXX_AR='$(AR)'
1509         CXX_ARFLAGS='$(ARFLAGS)'
1510         case $cf_cv_system_name in #(vi
1511         irix*) #(vi
1512             if test "$GXX" != yes ; then
1513                 CXX_AR='$(CXX)'
1514                 CXX_ARFLAGS='-ar -o'
1515             fi
1516             ;;
1517         sco3.2v5*) #(vi
1518             CXXLDFLAGS="-u main"
1519             ;;
1520         solaris2*)
1521             if test "$GXX" != yes ; then
1522                 CXX_AR='$(CXX)'
1523                 CXX_ARFLAGS='-xar -o'
1524             fi
1525             ;;
1526         esac
1527         AC_SUBST(CXXLDFLAGS)
1528         AC_SUBST(CXX_AR)
1529         AC_SUBST(CXX_ARFLAGS)
1530 else
1531         cf_cxx_library=no
1532         cf_cv_builtin_bool=1
1533
1534         # Just because we are not configuring against C++ right now does not
1535         # mean that a user will not want to use C++.  Some distributors disable
1536         # the C++ portion of this configuration as a shortcut (or just to avoid
1537         # compiling the demo in the c++ directory).  So we need a reasonable
1538         # default for the 'bool' type.
1539         #
1540         # Caveat: since the storage of the bool type is not standardized, it
1541         # may change.
1542
1543         if test "$NCURSES_BOOL" != auto ; then
1544                 cf_cv_type_of_bool=$NCURSES_BOOL
1545                 cf_cv_header_stdbool_h=0
1546         else
1547                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1548                         CF_BOOL_SIZE
1549                 else
1550                         AC_MSG_CHECKING(for fallback type of bool)
1551                         case "$host_cpu" in #(vi
1552                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1553                         *)      cf_cv_type_of_bool=int  ;;
1554                         esac
1555                         AC_MSG_RESULT($cf_cv_type_of_bool)
1556                 fi
1557         fi
1558 fi
1559 AC_SUBST(CXXLIBS)
1560
1561 # If the C compiler did not declare bool, and we did not determine that the C++
1562 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1563 # ncurses library use the same type as C++ bool.  Note that this allows one to
1564 # specify the type of bool in a configure-script option and postpone
1565 # integration with the C++ compiler provided that the types are compatible.
1566 USE_CXX_BOOL=1
1567 if test $cf_cv_cc_bool_type = 1
1568 then
1569         # oops: C has a bool.  Unlikely, but C++ could differ.
1570         USE_CXX_BOOL=0
1571 elif test $cf_cv_builtin_bool = 0
1572 then
1573         # C++ has no bool
1574         USE_CXX_BOOL=0
1575 else
1576         # this is the normal case
1577         USE_CXX_BOOL='defined(__cplusplus)'
1578 fi
1579 AC_SUBST(USE_CXX_BOOL)
1580
1581 CF_HELP_MESSAGE(Ada95 Binding Options:)
1582
1583 dnl If the Ada95 source-tree is present, add that to the build unless it will
1584 dnl not work, or was not requested.
1585 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1586
1587 dnl libtool does not know anything about GNAT, though a change made in 1998
1588 dnl provided for it "someday".  Disable the ada subtree if we are using
1589 dnl libtool -TD 20070714
1590         if test "$cf_with_ada" != "no" ; then
1591                 if test "$with_libtool" != "no"; then
1592                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1593                         cf_with_ada=no
1594                 fi
1595         fi
1596
1597 dnl Check for availability of GNU Ada Translator (GNAT).
1598 dnl At the moment we support no other Ada95 compiler.
1599         if test "$cf_with_ada" != "no" ; then
1600                 CF_PROG_GNAT
1601                 if test "$cf_cv_prog_gnat_correct" = yes; then
1602                         CF_ADD_ADAFLAGS(-gnatpn)
1603
1604                         # make ADAFLAGS consistent with CFLAGS
1605                         case "$CFLAGS" in
1606                         *-g*)
1607                                 CF_ADD_ADAFLAGS(-g)
1608                                 ;;
1609                         esac
1610                         case "$CFLAGS" in
1611                         *-O*)
1612                                 CF_ADD_ADAFLAGS(-O3)
1613                                 ;;
1614                         esac
1615
1616                         CF_GNAT_GENERICS
1617                         CF_GNAT_SIGINT
1618                         CF_GNAT_PRAGMA_UNREF
1619                         CF_GNAT_PROJECTS
1620
1621                         CF_WITH_ADA_COMPILER
1622
1623                         cf_ada_package=terminal_interface
1624                         AC_SUBST(cf_ada_package)
1625
1626                         CF_WITH_ADA_INCLUDE
1627                         CF_WITH_ADA_OBJECTS
1628                         CF_WITH_ADA_SHAREDLIB
1629                 fi
1630         fi
1631 else
1632         cf_with_ada=no
1633 fi
1634
1635 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1636 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1637 ###
1638 ### ticlib modules may be a separate library, otherwise contained in termlib.
1639 ### termlib modules may be a separate library, otherwise contained in ncurses.
1640 ###
1641 ### The of "+" or " " between the tokens controls the way the script
1642 ### chooses to split module lists into libraries.
1643 ###
1644 ### (see CF_LIB_RULES).
1645 AC_MSG_CHECKING(for library subsets)
1646 LIB_SUBSETS=
1647
1648 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1649         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1650         if test "$with_ticlib" != no ; then
1651                 LIB_SUBSETS="${LIB_SUBSETS} "
1652         else
1653                 LIB_SUBSETS="${LIB_SUBSETS}+"
1654         fi
1655 fi
1656
1657 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1658 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1659
1660 if test "$with_termlib" != no ; then
1661         LIB_SUBSETS="${LIB_SUBSETS} "
1662 else
1663         LIB_SUBSETS="${LIB_SUBSETS}+"
1664 fi
1665
1666 LIB_SUBSETS="${LIB_SUBSETS}base"
1667
1668 # Most term-driver calls are to tinfo, but some like init_pair are to the
1669 # base library (so it resides in base).
1670 if test "$with_term_driver" != no ; then
1671         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1672         case $cf_cv_system_name in #(vi
1673         *mingw32*) #(vi
1674                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1675                 ;;
1676         *) #(vi
1677                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1678                 ;;
1679         esac
1680 fi
1681
1682 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1683 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1684
1685 AC_MSG_RESULT($LIB_SUBSETS)
1686
1687 ### Construct the list of include-directories to be generated
1688 CF_INCLUDE_DIRS
1689 CF_ADA_INCLUDE_DIRS
1690
1691 ### Build up pieces for makefile rules
1692 AC_MSG_CHECKING(default library suffix)
1693 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1694 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1695 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1696
1697 AC_MSG_CHECKING(default library-dependency suffix)
1698 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1699 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1700 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1701
1702 AC_MSG_CHECKING(default object directory)
1703 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1704 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1705 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1706
1707 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1708 if test "$cf_with_cxx" = yes ; then
1709 AC_MSG_CHECKING(c++ library-dependency suffix)
1710 if test "$with_libtool" != "no"; then
1711         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1712 else
1713         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)dnl we normally make a static library
1714 fi
1715 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1716 AC_SUBST(CXX_LIB_SUFFIX)
1717 fi
1718
1719 # do not want -ldl in build except as needed for -lncurses dependency
1720 if test "$with_dlsym" = yes ; then
1721 if test $DFT_LWR_MODEL = shared || \
1722    test $DFT_LWR_MODEL = libtool ; then
1723         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1724 fi
1725 fi
1726 ### Set up low-level terminfo dependencies for makefiles.
1727
1728 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1729 # do not need libdl
1730 TICS_LIST=
1731 if test "$with_dlsym" = yes ; then
1732         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1733 fi
1734
1735 if test "$with_ticlib" != no ; then
1736
1737         if test "$with_ticlib" != yes ; then
1738                 TICS_NAME=$with_ticlib
1739                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1740                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1741                 TICS_LIB_SUFFIX="${with_ticlib}"
1742         else
1743                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1744                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1745                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1746         fi
1747         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1748 else
1749         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1750 fi
1751 AC_SUBST(TICS_ARG_SUFFIX)
1752 AC_SUBST(TICS_DEP_SUFFIX)
1753 AC_SUBST(TICS_LIB_SUFFIX)
1754 AC_SUBST(TICS_ARGS)
1755
1756 if test "$with_termlib" != no ; then
1757
1758         if test "$with_termlib" != yes ; then
1759                 TINFO_NAME=$with_termlib
1760                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1761                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1762                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1763                 TINFO_LIB_SUFFIX="${with_termlib}"
1764         else
1765                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1766                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1767                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1768                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1769         fi
1770
1771         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1772         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1773         if test "$DFT_LWR_MODEL" = "libtool"; then
1774                 TEST_ARGS="${TEST_DEPS}"
1775                 TEST_ARG2="${TEST_DEP2}"
1776                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1777                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1778                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1779         else
1780                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1781                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1782                 TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1783                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1784                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1785         fi
1786 else
1787         # the next lines are needed for linking libtic over libncurses
1788         TINFO_NAME=${LIB_NAME}
1789         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1790         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1791         if test "$with_tic_depends" = yes ; then
1792                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1793         else
1794                 TICS_LIST="$SHLIB_LIST"
1795         fi
1796
1797         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1798 fi
1799
1800 if test "$DFT_LWR_MODEL" = shared ; then
1801         case $cf_cv_system_name in #(vi
1802         cygwin*)
1803                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1804                 TINFO_SUFFIX=.dll
1805                 ;;
1806         esac
1807 fi
1808
1809 AC_SUBST(TINFO_ARG_SUFFIX)
1810 AC_SUBST(TINFO_DEP_SUFFIX)
1811 AC_SUBST(TINFO_LIB_SUFFIX)
1812 AC_SUBST(TINFO_ARGS)
1813
1814 if test "$with_dlsym" = yes ; then
1815         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1816 fi
1817
1818 if test "$DFT_LWR_MODEL" = "libtool"; then
1819     OBJEXT=lo
1820 fi
1821
1822 # needed for Ada95
1823 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1824 AC_SUBST(TINFO_ARGS2)
1825
1826 case $DFT_LWR_MODEL in
1827 normal|debug|profile)
1828         CF_LDFLAGS_STATIC
1829         ;;
1830 esac
1831
1832 AC_MSG_CHECKING(where we will install curses.h)
1833 test "$with_overwrite" = no && \
1834 test "x$includedir" = 'x${prefix}/include' && \
1835         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1836 AC_MSG_RESULT($includedir)
1837
1838 ### Resolve a conflict between normal and wide-curses by forcing applications
1839 ### that will need libutf8 to add it to their configure script.
1840 if test "$with_overwrite" != no ; then
1841 if test "$NCURSES_LIBUTF8" = 1 ; then
1842         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1843         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1844 fi
1845 fi
1846 WITH_OVERWRITE=$with_overwrite
1847
1848 AC_SUBST(WITH_OVERWRITE)
1849 AC_SUBST(TICS_LIST)
1850 AC_SUBST(TINFO_LIST)
1851 AC_SUBST(SHLIB_LIST)
1852
1853 # used to separate tack out of the tree
1854 NCURSES_TREE=
1855 AC_SUBST(NCURSES_TREE)
1856
1857 ### predefined stuff for the test programs
1858 AC_DEFINE(HAVE_SLK_COLOR)
1859
1860 ### Construct the list of subdirectories for which we'll customize makefiles
1861 ### with the appropriate compile-rules.
1862
1863 CF_SRC_MODULES($modules_to_build)
1864
1865 if test "$cf_with_ada" != "no" && test "$cf_cv_prog_gnat_correct" != "no"; then
1866    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1867    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${DFT_ARG_SUFFIX}-config.1:man/MKada_config.in"
1868 fi
1869
1870 CF_DIRS_TO_MAKE
1871
1872 # symbols that differ when compiling Ada95 by itself.
1873 NCURSES_SHLIB2='sh $(top_srcdir)/misc/shlib'
1874 AC_SUBST(NCURSES_SHLIB2)
1875
1876 # values to use as strings
1877 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR')
1878
1879 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1880
1881 ### Now that we're done running tests, add the compiler-warnings, if any
1882 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1883
1884 ### Define substitutions for header files to avoid name-pollution
1885 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1886 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1887 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1888
1889 ################################################################################
1890 test "$use_database" = yes && \
1891 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1892
1893 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1894 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${DFT_ARG_SUFFIX}${cf_cv_abi_version}-config.1:man/MKncu_config.in"
1895
1896 if test x"$enable_pc_files" = xyes ; then \
1897 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1898 MAKE_PC_FILES=
1899 else
1900 MAKE_PC_FILES="#"
1901 fi
1902 AC_SUBST(MAKE_PC_FILES)
1903 AC_SUBST(cross_compiling)
1904
1905 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
1906 if test -n "$FALLBACK_LIST"
1907 then
1908         if test "$TIC_PATH" = unknown
1909         then
1910                 AC_MSG_WARN(no tic program found for fallbacks)
1911         fi
1912 fi
1913 AC_SUBST(TIC_PATH)
1914
1915 if test "x$cf_with_tests" != xno ; then
1916         MAKE_TESTS=
1917 else
1918         MAKE_TESTS="#"
1919 fi
1920 AC_SUBST(MAKE_TESTS)
1921
1922 ADAHTML_DIR=../../doc/html/ada
1923 AC_SUBST(ADAHTML_DIR)
1924
1925 SUB_SCRIPTS=
1926 case $cf_cv_system_name in #(vi
1927 *mingw32*) #(vi
1928         SUB_SCRIPTS="mk-dlls.sh"
1929         ;;
1930 esac
1931
1932 AC_OUTPUT( \
1933         include/MKterm.h.awk \
1934         include/curses.head:include/curses.h.in \
1935         include/ncurses_dll.h \
1936         include/termcap.h \
1937         include/unctrl.h \
1938         $SUB_SCRIPTS \
1939         $SUB_MAKEFILES \
1940         Makefile,[
1941 if test "x$cf_with_tests" != xno ; then
1942         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LINK"], test)
1943 fi
1944 CF_LIB_RULES($SRC_SUBDIRS)
1945
1946 if test "x$cf_with_ada" != xno ; then
1947 if test -z "$USE_OLD_MAKERULES" ; then
1948         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
1949 fi
1950 fi
1951 ],[
1952 ### Special initialization commands, used to pass information from the
1953 ### configuration-run into config.status
1954
1955 AWK="$AWK"
1956 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1957 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1958 ECHO_LINK="$ECHO_LINK"
1959 LDCONFIG="$LDCONFIG"
1960 LIBTOOL_VERSION="$LIBTOOL_VERSION"
1961 LIB_NAME="$LIB_NAME"
1962 LIB_SUBSETS="$LIB_SUBSETS"
1963 LIB_SUFFIX="$LIB_SUFFIX"
1964 LIB_TRACING="$LIB_TRACING"
1965 LN_S="$LN_S"
1966 MAKE_TERMINFO="$MAKE_TERMINFO"
1967 NCURSES_MAJOR="$NCURSES_MAJOR"
1968 NCURSES_MINOR="$NCURSES_MINOR"
1969 NCURSES_OSPEED="$NCURSES_OSPEED"
1970 NCURSES_PATCH="$NCURSES_PATCH"
1971 SRC_SUBDIRS="$SRC_SUBDIRS"
1972 TERMINFO="$TERMINFO"
1973 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1974 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1975 TICS_NAME="$TICS_NAME"
1976 TIC_PATH="$TIC_PATH"
1977 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1978 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1979 TINFO_NAME="$TINFO_NAME"
1980 TINFO_SUFFIX="$TINFO_SUFFIX"
1981 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
1982 WITH_CURSES_H="$with_curses_h"
1983 WITH_ECHO="$with_echo"
1984 WITH_OVERWRITE="$with_overwrite"
1985 cf_LIST_MODELS="$cf_list_models"
1986 cf_cv_abi_version="$cf_cv_abi_version"
1987 cf_cv_do_relink="$cf_cv_do_relink"
1988 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1989 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1990 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1991 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1992 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1993 cf_cv_rel_version="$cf_cv_rel_version"
1994 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1995 cf_cv_shared_soname='$cf_cv_shared_soname'
1996 cf_cv_shlib_version="$cf_cv_shlib_version"
1997 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1998 cf_cv_system_name="$cf_cv_system_name"
1999 cf_with_ada="$cf_with_ada"
2000 cf_with_cxx_binding="$cf_with_cxx_binding"
2001 cf_with_manpages="$cf_with_manpages"
2002 cf_with_tests="$cf_with_tests"
2003 host="$host"
2004 target="$target"
2005
2006 ],cat)dnl
2007 ${MAKE:-make} preinstall