configure.in

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2020,2021 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: configure.in,v 1.729 2021/01/09 11:20:52 tom Exp $
  33 dnl Process this file with autoconf to produce a configure script.
  34 dnl
  35 dnl For additional information, see
  36 dnl     https://invisible-island.net/autoconf/
  37 dnl     https://invisible-island.net/autoconf/my-autoconf.html
  38 dnl
  39 dnl ---------------------------------------------------------------------------
  40 AC_PREREQ(2.52.20210101)
  41 AC_REVISION($Revision: 1.729 $)
  42 AC_INIT(ncurses/base/lib_initscr.c)
  43 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  44
  45 AC_DEFUN([AC_PATH_XTRA],[])dnl ignore dependencies on this
  46
  47 CF_TOP_BUILDDIR
  48 CF_SUBST_NCURSES_VERSION
  49 CF_VERSION_INFO(NCURSES,ncurses)
  50
  51 CF_WITH_REL_VERSION(NCURSES)
  52 CF_NCURSES_WITH_ABI_VERSION
  53
  54 CF_WITH_SYSTYPE
  55
  56 ###     Save the given $CFLAGS to allow user-override.
  57 cf_user_CFLAGS="$CFLAGS"
  58
  59 ###     Default install-location
  60 CF_CFG_DEFAULTS
  61 ### Defaults for ncurses ABI
  62 CF_ABI_DEFAULTS
  63
  64 ###     Checks for programs.
  65 AC_ARG_WITH(ada,
  66         [  --without-ada           suppress check for Ada compiler, don't build demo],
  67         [cf_with_ada=$withval],
  68         [cf_with_ada=yes])
  69
  70 if test "x$cf_with_ada" = xyes
  71 then
  72         cf_prog_cc="gnatgcc gcc cc"
  73 else
  74         cf_prog_cc="gcc cc"
  75 fi
  76 CF_PROG_CC($cf_prog_cc)
  77
  78 AC_PROG_CPP
  79 AC_PROG_GCC_TRADITIONAL
  80 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
  81 CF_PROG_LDCONFIG
  82
  83 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  84 dnl                             configure script by not letting us test if C++
  85 dnl                             is present, making this option necessary.
  86 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  87 AC_ARG_WITH(cxx,
  88         [  --without-cxx           do not adjust ncurses bool to match C++],
  89         [cf_with_cxx=$withval],
  90         [cf_with_cxx=yes])
  91 AC_MSG_RESULT($cf_with_cxx)
  92 if test "X$cf_with_cxx" = Xno ; then
  93         CXX=""
  94         GXX=""
  95 else
  96         # with autoconf 2.13, we can change the error to a warning:
  97         pushdef([AC_MSG_ERROR],
  98                 [AC_MSG_RESULT(no)
  99                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
 100                 cf_with_cxx=no; CXX=""; GXX="";])dnl
 101         AC_PROG_CXX
 102         popdef([AC_MSG_ERROR])dnl
 103
 104         AC_LANG_PUSH(C++)
 105         if test "x$cf_with_cxx" != xno
 106         then
 107                 # Several of the C++ configurations do not work, particularly when
 108                 # cross-compiling (20140913 -TD)
 109                 AC_MSG_CHECKING(if $CXX works)
 110
 111                 save_CPPFLAGS="$CPPFLAGS"
 112                 eval cf_includedir=${includedir}
 113                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
 114                 AC_TRY_COMPILE([
 115 #include <stdlib.h>
 116 #include <stdio.h>
 117 ],
 118                 [
 119                 printf("Hello world!\n")
 120                 ],
 121                 [cf_cxx_works=yes],
 122                 [cf_cxx_works=no])
 123                 CPPFLAGS="$save_CPPFLAGS"
 124
 125                 AC_MSG_RESULT($cf_cxx_works)
 126                 if test "x$cf_cxx_works" = xno
 127                 then
 128                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
 129                         cf_with_cxx=no; CXX=""; GXX="";
 130                 fi
 131         fi
 132         AC_LANG_POP
 133
 134         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
 135         if test "$CXX" = "g++" ; then
 136                 AC_PATH_PROG(CXX,g++)
 137         fi
 138         case "x$CXX" in
 139         (x|xg++)
 140                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
 141                 cf_with_cxx=no; CXX=""; GXX="";
 142                 ;;
 143         esac
 144 fi
 145
 146 CF_GXX_VERSION
 147 case "$GXX_VERSION" in
 148 ([[1-9]][[0-9]].*)
 149         ;;
 150 (1.*|2.[[0-6]]*)
 151         AC_MSG_WARN(templates do not work)
 152         ;;
 153 esac
 154
 155 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 156 AC_ARG_WITH(cxx-binding,
 157         [  --without-cxx-binding   do not build C++ binding and demo],
 158         [cf_with_cxx_binding=$withval],
 159         [cf_with_cxx_binding=$cf_with_cxx])
 160 AC_MSG_RESULT($cf_with_cxx_binding)
 161
 162 AC_MSG_CHECKING(if you want to build with Ada)
 163 AC_MSG_RESULT($cf_with_ada)
 164
 165 AC_MSG_CHECKING(if you want to install terminal database)
 166 AC_ARG_ENABLE(db-install,
 167         [  --disable-db-install    suppress install of terminal database],
 168         [cf_with_db_install=$enableval],
 169         [cf_with_db_install=yes])
 170 AC_MSG_RESULT($cf_with_db_install)
 171
 172 AC_MSG_CHECKING(if you want to install manpages)
 173 AC_ARG_WITH(manpages,
 174         [  --without-manpages      suppress install of manpages],
 175         [cf_with_manpages=$withval],
 176         [cf_with_manpages=yes])
 177 AC_MSG_RESULT($cf_with_manpages)
 178
 179 AC_MSG_CHECKING(if you want to build programs such as tic)
 180 AC_ARG_WITH(progs,
 181         [  --without-progs         suppress build/install with programs (e.g., tic)],
 182         [cf_with_progs=$withval],
 183         [cf_with_progs=yes])
 184 AC_MSG_RESULT($cf_with_progs)
 185
 186 if test -f "$srcdir/tack/tack.h" ; then
 187         if test "x$cross_compiling" = xyes ; then
 188                 CF_VERBOSE(ignoring tack because we are cross-compiling)
 189                 cf_with_tack=no
 190         else
 191                 AC_MSG_CHECKING(if you want to build the tack program)
 192                 AC_ARG_WITH(tack,
 193                         [  --without-tack          suppress build/install with tack program],
 194                         [cf_with_tack=$withval],
 195                         [cf_with_tack=$cf_with_progs])
 196                 AC_MSG_RESULT($cf_with_tack)
 197         fi
 198 else
 199         cf_with_tack=no
 200 fi
 201
 202 AC_MSG_CHECKING(if you want to build test-programs)
 203 AC_ARG_WITH(tests,
 204         [  --without-tests         suppress build/install with test-programs],
 205         [cf_with_tests=$withval],
 206         [cf_with_tests=yes])
 207 AC_MSG_RESULT($cf_with_tests)
 208
 209 AC_MSG_CHECKING(if you wish to install curses.h)
 210 AC_ARG_WITH(curses-h,
 211         [  --without-curses-h      install curses.h as ncurses.h only],
 212         [with_curses_h=$withval],
 213         [with_curses_h=yes])
 214 AC_MSG_RESULT($with_curses_h)
 215
 216 modules_to_build="ncurses"
 217 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
 218 test "X$cf_with_tack"  != Xno && modules_to_build="$modules_to_build tack"
 219 modules_to_build="$modules_to_build panel menu form"
 220
 221 AC_ARG_PROGRAM
 222
 223 CF_PROG_AWK
 224 CF_PROG_INSTALL
 225 CF_PROG_LINT
 226 CF_PROG_LN_S
 227
 228 AC_SYS_LONG_FILE_NAMES
 229
 230 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
 231 # of package conflict.
 232 cf_config_suffix=
 233 AC_ARG_WITH(config-suffix,
 234         [  --with-config-suffix=X  suffixes ncursesXX-config file],
 235         [case "x$withval" in
 236         (xyes|xno)
 237                 AC_MSG_WARN(expected a value for config-suffix option)
 238                 ;;
 239         (*)     cf_config_suffix="$withval"
 240                 ;;
 241         esac])
 242 AC_SUBST(cf_config_suffix)
 243
 244 # If we find pkg-config, check if we should install the ".pc" files.
 245 CF_PKG_CONFIG
 246 CF_WITH_PKG_CONFIG_LIBDIR
 247 CF_ENABLE_PC_FILES
 248 if test -z "$MAKE_PC_FILES"
 249 then
 250         AC_MSG_CHECKING(for suffix to add to pc-files)
 251 AC_ARG_WITH(pc-suffix,
 252         [  --with-pc-suffix        suffixes pc-files],
 253         [case "x$withval" in
 254         (xyes|xno)
 255                 PC_MODULE_SUFFIX=
 256                 ;;
 257         (*)     PC_MODULE_SUFFIX="$withval"
 258                 ;;
 259         esac])
 260         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
 261         AC_MSG_RESULT($PC_MODULE_SUFFIX)
 262         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
 263         AC_SUBST(PC_MODULE_SUFFIX)
 264 fi
 265
 266 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 267 AC_ARG_ENABLE(mixed-case,
 268         [  --enable-mixed-case     tic should assume mixed-case filenames],
 269         [enable_mixedcase=$enableval],
 270         [enable_mixedcase=auto])
 271 AC_MSG_RESULT($enable_mixedcase)
 272 if test "$enable_mixedcase" = "auto" ; then
 273         CF_MIXEDCASE_FILENAMES
 274 else
 275         cf_cv_mixedcase=$enable_mixedcase
 276         if test "x$enable_mixedcase" = "xyes" ; then
 277                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
 278         fi
 279 fi
 280
 281 # do this after mixed-case option (tags/TAGS is not as important as tic).
 282 AC_PROG_MAKE_SET
 283 CF_MAKE_TAGS
 284 CF_MAKEFLAGS
 285
 286 dnl These are standard among *NIX systems, but not when cross-compiling
 287 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 288 AC_CHECK_TOOL(LD, ld, ld)
 289 AC_CHECK_TOOL(AR, ar, ar)
 290 AC_CHECK_TOOL(NM, nm, nm)
 291 CF_AR_FLAGS
 292
 293 dnl Special option for use by system-builders: the install-prefix is used to
 294 dnl adjust the location into which the actual install is done, so that an
 295 dnl archive can be built without modifying the host system's configuration.
 296 AC_MSG_CHECKING(if you have specified an install-prefix)
 297 AC_ARG_WITH(install-prefix,
 298         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 299         [case "x$withval" in
 300         (xyes|xno)
 301                 ;;
 302         (*)     DESTDIR="$withval"
 303                 ;;
 304         esac])
 305 AC_MSG_RESULT($DESTDIR)
 306 AC_SUBST(DESTDIR)
 307
 308 ###############################################################################
 309 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 310 # If we're cross-compiling, allow the user to override the tools and their
 311 # options.  The configure script is oriented toward identifying the host
 312 # compiler, etc., but we need a build compiler to generate parts of the source.
 313
 314 case "$cf_cv_system_name" in
 315 (*-msvc*)
 316         LDFLAGS="$LDFLAGS user32.lib"
 317         export LDFLAGS
 318         ;;
 319 esac
 320
 321 CF_BUILD_CC
 322
 323 ###############################################################################
 324 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 325
 326 ### Options to allow the user to specify the set of libraries which are used.
 327 ### Use "--without-normal --with-shared" to allow the default model to be
 328 ### shared, for example.
 329 cf_list_models=""
 330 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 331
 332 CF_WITH_LIBTOOL
 333 if test "$with_libtool" != "no" ; then
 334
 335 cf_list_models="$cf_list_models libtool"
 336
 337 else
 338
 339 AC_MSG_CHECKING(if you want to build shared libraries)
 340 AC_ARG_WITH(shared,
 341         [  --with-shared           generate shared-libraries],
 342         [with_shared=$withval],
 343         [with_shared=no])
 344 AC_MSG_RESULT($with_shared)
 345 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
 346
 347 AC_MSG_CHECKING(if you want to build static libraries)
 348 AC_ARG_WITH(normal,
 349         [  --with-normal           generate normal-libraries (default)],
 350         [with_normal=$withval],
 351         [with_normal=yes])
 352 AC_MSG_RESULT($with_normal)
 353 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
 354
 355 AC_MSG_CHECKING(if you want to build debug libraries)
 356 AC_ARG_WITH(debug,
 357         [  --with-debug            generate debug-libraries (default)],
 358         [with_debug=$withval],
 359         [with_debug=yes])
 360 AC_MSG_RESULT($with_debug)
 361 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
 362
 363 AC_MSG_CHECKING(if you want to build profiling libraries)
 364 AC_ARG_WITH(profile,
 365         [  --with-profile          generate profile-libraries],
 366         [with_profile=$withval],
 367         [with_profile=no])
 368 AC_MSG_RESULT($with_profile)
 369 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
 370
 371 fi
 372
 373 if test "X$cf_with_cxx_binding" != Xno; then
 374 if test "x$with_shared" = "xyes"; then
 375 AC_MSG_CHECKING(if you want to build C++ shared libraries)
 376 AC_ARG_WITH(cxx-shared,
 377         [  --with-cxx-shared       generate C++ shared-libraries],
 378         [with_shared_cxx=$withval],
 379         [with_shared_cxx=no])
 380 AC_MSG_RESULT($with_shared_cxx)
 381 fi
 382 fi
 383
 384 ###############################################################################
 385
 386 AC_MSG_CHECKING(for specified models)
 387 test -z "$cf_list_models" && cf_list_models=normal
 388 dnl If we use libtool to generate libraries, then it must be the only
 389 dnl specified model.
 390 test "$with_libtool" != "no" && cf_list_models=libtool
 391 AC_MSG_RESULT($cf_list_models)
 392
 393 ### Use the first model as the default, and save its suffix for use in building
 394 ### up test-applications.
 395 AC_MSG_CHECKING(for default model)
 396 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 397 AC_MSG_RESULT($DFT_LWR_MODEL)
 398
 399 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 400
 401 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 402 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 403
 404 TICS_NAME=tic
 405 AC_SUBST(TICS_NAME)
 406
 407 TINFO_NAME=tinfo
 408 AC_SUBST(TINFO_NAME)
 409
 410 LIB_NAME=ncurses
 411 AC_SUBST(LIB_NAME)
 412
 413 LIB_DIR=../lib
 414 LIB_2ND=../../lib
 415
 416 CF_WITH_LIB_PREFIX(cf_prefix)
 417
 418 LIB_SUFFIX=
 419 AC_SUBST(LIB_SUFFIX)
 420 CF_PATHSEP
 421
 422 ###############################################################################
 423
 424 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 425 AC_ARG_WITH(termlib,
 426         [  --with-termlib          generate separate terminfo library],
 427         [with_termlib=$withval],
 428         [with_termlib=no])
 429 AC_MSG_RESULT($with_termlib)
 430
 431 AC_MSG_CHECKING(if you want to build a separate tic library)
 432 AC_ARG_WITH(ticlib,
 433         [  --with-ticlib           generate separate tic library],
 434         [with_ticlib=$withval],
 435         [with_ticlib=no])
 436 AC_MSG_RESULT($with_ticlib)
 437
 438 dnl Not all ports of gcc support the -g option
 439
 440 if test X"$CC_G_OPT" = X"" ; then
 441         CC_G_OPT='-g'
 442         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
 443 fi
 444 AC_SUBST(CC_G_OPT)
 445
 446 if test X"$CXX_G_OPT" = X"" ; then
 447         CXX_G_OPT='-g'
 448         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
 449 fi
 450 AC_SUBST(CXX_G_OPT)
 451
 452 AC_MSG_CHECKING(for default loader flags)
 453 case "$DFT_LWR_MODEL" in
 454 (libtool) LD_MODEL=''   ;;
 455 (normal)  LD_MODEL=''   ;;
 456 (debug)   LD_MODEL=$CC_G_OPT ;;
 457 (profile) LD_MODEL='-pg';;
 458 (shared)  LD_MODEL=''   ;;
 459 esac
 460 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 461 AC_MSG_RESULT($LD_MODEL)
 462
 463 case "$DFT_LWR_MODEL" in
 464 (shared)
 465 CF_ENABLE_RPATH
 466 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 467 AC_ARG_ENABLE(relink,
 468 [  --disable-relink        relink shared libraries during install],
 469 [cf_cv_do_relink=$enableval],
 470 [cf_cv_do_relink=yes])
 471 AC_MSG_RESULT($cf_cv_do_relink)
 472         ;;
 473 esac
 474
 475 # we will build libraries one-level down.
 476 rel_builddir=..
 477 CF_SHARED_OPTS
 478 for model in $cf_list_models ; do
 479         case "$model" in
 480         (libtool)
 481                 CF_WITH_LIBTOOL_OPTS
 482                 CF_WITH_EXPORT_SYMS
 483                 ;;
 484         (shared)
 485                 if test "$CC_SHARED_OPTS" = "unknown"; then
 486                         AC_ERROR(Shared libraries are not supported in this version)
 487                 fi
 488                 # workaround for inept transition to PIE vs PIC...
 489                 AC_MSG_CHECKING(if current CFLAGS link properly)
 490                 AC_TRY_LINK(
 491                         [#include <stdio.h>],
 492                         [printf("Hello work\\n");],
 493                         [cf_cflags_work=yes],
 494                         [cf_cflags_work=no])
 495                 AC_MSG_RESULT($cf_cflags_work)
 496                 if test "$cf_cflags_work" = no
 497                 then
 498                         CF_VERBOSE(try to work around by appending shared-options)
 499                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
 500                 fi
 501                 CF_WITH_VERSIONED_SYMS
 502                 ;;
 503         esac
 504 done
 505
 506 ### Checks for special libraries, must be done up-front.
 507 SHLIB_LIST=""
 508 CF_WITH_GPM
 509 if test "$with_gpm" != no ; then
 510         AC_MSG_CHECKING(if you want to load GPM dynamically)
 511         AC_ARG_WITH(dlsym,
 512                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 513                 [with_dlsym=$withval],
 514                 [with_dlsym=yes])
 515         AC_MSG_RESULT($with_dlsym)
 516         if test "x$with_dlsym" = xyes ; then
 517                 CF_FUNC_DLSYM
 518                 if test "x$with_gpm" != xyes ; then
 519                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 520                         cf_cv_gpm_soname="$with_gpm"
 521                 else
 522                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 523                 fi
 524                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
 525                 SHLIB_LIST="-ldl $SHLIB_LIST"
 526                 CF_ADD_LIB(dl,PRIVATE_LIBS)
 527         else
 528                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 529                 CF_ADD_LIB(gpm,TEST_LIBS)
 530                 CF_ADD_LIB(gpm,PRIVATE_LIBS)
 531         fi
 532         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
 533         CF_CHECK_GPM_WGETCH
 534 fi
 535
 536 CF_WITH_PCRE2
 537 CF_WITH_SYSMOUSE
 538
 539 # pretend that ncurses==ncursesw==ncursest
 540 AC_MSG_CHECKING(if you want to disable library suffixes)
 541 CF_ARG_DISABLE(lib-suffixes,
 542         [  --disable-lib-suffixes  disable library suffixes],
 543         [disable_lib_suffixes=yes],
 544         [disable_lib_suffixes=no],
 545         no)
 546 AC_MSG_RESULT($disable_lib_suffixes)
 547
 548 ### If we're building with rpath, try to link non-standard libs that way too.
 549 if test "$DFT_LWR_MODEL" = "shared" && test "x$cf_cv_enable_rpath" != xno; then
 550         CF_DISABLE_RPATH_HACK
 551 fi
 552
 553 ### Depending on the system, someone may use rpath to build ncurses but not
 554 # want users of the package to rely upon that feature.  Give those people an
 555 # option to suppress that detail from EXTRA_LDFLAGS.
 556 EXTRA_PKG_LDFLAGS="$EXTRA_LDFLAGS"
 557 if test -n "$EXTRA_PKG_LDFLAGS"
 558 then
 559         AC_MSG_CHECKING(if you want to disable extra LDFLAGS for package-scripts)
 560         CF_ARG_DISABLE(pkg-ldflags,
 561                 [  --disable-pkg-ldflags   disable extra LDFLAGS for package-scripts],
 562                 [disable_pkg_ldflags=yes],
 563                 [disable_pkg_ldflags=no],
 564                 no)
 565         AC_MSG_RESULT($disable_pkg_ldflags)
 566         test "$disable_pkg_ldflags" = yes && EXTRA_PKG_LDFLAGS=
 567 fi
 568 AC_SUBST(EXTRA_PKG_LDFLAGS)
 569
 570 ###############################################################################
 571 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 572
 573 ###     use option --with-extra-suffix to append suffix to headers and libraries
 574 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
 575 EXTRA_SUFFIX=
 576 AC_ARG_WITH(extra-suffix,
 577         [  --with-extra-suffix=X   append extra suffix to header/library paths],
 578         [case x$withval in
 579         (xno)
 580                 ;;
 581         (xyes|x)
 582                 EXTRA_SUFFIX=$cf_cv_abi_version
 583                 ;;
 584         (*)
 585                 EXTRA_SUFFIX=$withval
 586                 ;;
 587         esac
 588         ])
 589 AC_MSG_RESULT($EXTRA_SUFFIX)
 590 AC_SUBST(EXTRA_SUFFIX)
 591
 592 ###     use option --disable-overwrite to leave out the link to -lcurses
 593 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 594 AC_ARG_ENABLE(overwrite,
 595         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
 596         [with_overwrite=$enableval],
 597         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 598 AC_MSG_RESULT($with_overwrite)
 599
 600 AC_MSG_CHECKING(if external terminfo-database is used)
 601 AC_ARG_ENABLE(database,
 602         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 603         [use_database=$enableval],
 604         [use_database=yes])
 605 AC_MSG_RESULT($use_database)
 606
 607 case "$host_os" in
 608 (os2*)
 609         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 610         ;;
 611 (*)
 612         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 613         ;;
 614 esac
 615 AC_SUBST(TERMINFO_SRC)
 616
 617 NCURSES_USE_DATABASE=0
 618 if test "$use_database" != no ; then
 619         NCURSES_USE_DATABASE=1
 620
 621         AC_MSG_CHECKING(which terminfo source-file will be installed)
 622         AC_ARG_WITH(database,
 623                 [  --with-database=XXX     specify terminfo source to install],
 624                 [TERMINFO_SRC=$withval])
 625         AC_MSG_RESULT($TERMINFO_SRC)
 626
 627         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 628         AC_ARG_WITH(hashed-db,
 629                 [  --with-hashed-db        specify hashed-database library],,
 630                 [with_hashed_db=no])
 631         AC_MSG_RESULT($with_hashed_db)
 632 else
 633         with_hashed_db=no
 634 fi
 635 AC_SUBST(NCURSES_USE_DATABASE)
 636
 637 AC_MSG_CHECKING(for list of fallback descriptions)
 638 AC_ARG_WITH(fallbacks,
 639         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 640         [with_fallback=$withval],
 641         [with_fallback=])
 642 AC_MSG_RESULT($with_fallback)
 643
 644 case ".$with_fallback" in
 645 (.|.no)
 646         FALLBACK_LIST=
 647         ;;
 648 (.yes)
 649         AC_MSG_WARN(expected a list of terminal descriptions)
 650         ;;
 651 (*)
 652         FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 653         ;;
 654 esac
 655
 656 # The fallback feature in ncurses relies upon tic/infocmp outside the build
 657 # tree for generating the terminal descriptions that will be compiled into the
 658 # library.  If your toolchain is old, it may not handle current terminal
 659 # databases.  Use configure-options to point to the tools which will be used,
 660 # rather than the first ones found on the $PATH.
 661 AC_CHECK_TOOL(TIC, tic)
 662 AC_CHECK_TOOL(INFOCMP, infocmp)
 663 if test -n "$FALLBACK_LIST"
 664 then
 665         CF_WITH_PATH_PROG(TIC,     tic,     [for fallbacks], $PATH:/usr/local/ncurses/bin)
 666         CF_WITH_PATH_PROG(INFOCMP, infocmp, [for fallbacks], $PATH:/usr/local/ncurses/bin)
 667         test -z "$TIC" && FALLBACK_LIST=
 668         test -z "$INFOCMP" && FALLBACK_LIST=
 669         if test -z "$FALLBACK_LIST"
 670         then
 671                 AC_MSG_WARN(ignoring fallback option because tic/infocmp are not available)
 672         fi
 673 fi
 674 AC_SUBST(TIC)
 675 AC_SUBST(INFOCMP)
 676
 677 USE_FALLBACKS=
 678 test -z "$FALLBACK_LIST" && USE_FALLBACKS="#"
 679 AC_SUBST(FALLBACK_LIST)
 680 AC_SUBST(USE_FALLBACKS)
 681
 682 AC_MSG_CHECKING(if you want modern xterm or antique)
 683 AC_ARG_WITH(xterm-new,
 684         [  --without-xterm-new     specify if xterm terminfo should be old version],
 685         [with_xterm_new=$withval],
 686         [with_xterm_new=yes])
 687 case "$with_xterm_new" in
 688 (no) with_xterm_new=xterm-old;;
 689 (*)      with_xterm_new=xterm-new;;
 690 esac
 691 AC_MSG_RESULT($with_xterm_new)
 692 WHICH_XTERM=$with_xterm_new
 693 AC_SUBST(WHICH_XTERM)
 694
 695 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 696 AC_ARG_WITH(xterm-kbs,
 697         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
 698         [with_xterm_kbs=$withval],
 699         [with_xterm_kbs=BS])
 700 case x$with_xterm_kbs in
 701 (xyes|xno|xBS|xbs|x8)
 702         with_xterm_kbs=BS
 703         ;;
 704 (xDEL|xdel|x127)
 705         with_xterm_kbs=DEL
 706         ;;
 707 (*)
 708         with_xterm_kbs=$withval
 709         ;;
 710 esac
 711 AC_MSG_RESULT($with_xterm_kbs)
 712 XTERM_KBS=$with_xterm_kbs
 713 AC_SUBST(XTERM_KBS)
 714
 715 MAKE_TERMINFO=
 716 if test "$use_database" = no ; then
 717         TERMINFO="${datadir}/terminfo"
 718         MAKE_TERMINFO="#"
 719 else
 720
 721 AC_MSG_CHECKING(for list of terminfo directories)
 722 CF_WITH_PATHLIST(terminfo-dirs,
 723         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 724         TERMINFO_DIRS,
 725         DATADIR/terminfo,
 726         ${datadir}/terminfo)
 727 AC_MSG_RESULT($TERMINFO_DIRS)
 728 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
 729
 730 case "x$TERMINFO" in
 731 x???:*)
 732         AC_MSG_WARN(ignoring non-directory/file TERMINFO value)
 733         unset TERMINFO
 734         ;;
 735 esac
 736
 737 AC_MSG_CHECKING(for default terminfo directory)
 738 CF_WITH_PATH(default-terminfo-dir,
 739         [  --with-default-terminfo-dir=DIR default terminfo directory],
 740         TERMINFO,
 741         DATADIR/terminfo,
 742         ${datadir}/terminfo)
 743 AC_MSG_RESULT($TERMINFO)
 744 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
 745
 746 fi
 747
 748 AC_SUBST(TERMINFO)
 749 AC_SUBST(MAKE_TERMINFO)
 750
 751 ###     use option --disable-big-core to make tic run on small machines
 752 ###     We need 4Mb, check if we can allocate 50% more than that.
 753 AC_MSG_CHECKING(if big-core option selected)
 754 AC_ARG_ENABLE(big-core,
 755         [  --disable-big-core      assume machine has little memory],
 756         [with_big_core=$enableval],
 757         [AC_TRY_RUN([
 758 #include <stdlib.h>
 759 #include <string.h>
 760 int main() {
 761         unsigned long n = 6000000L;
 762         char *s = malloc(n);
 763         if (s != 0)
 764                 s[0] = s[n-1] = 0;
 765         ${cf_cv_main_return:-return}(s == 0);
 766 }],
 767         [with_big_core=yes],
 768         [with_big_core=no],
 769         [with_big_core=no])])
 770 AC_MSG_RESULT($with_big_core)
 771 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
 772
 773 ### ISO C only guarantees 512-char strings, we have tables which load faster
 774 ### when constructed using "big" strings.  More than the C compiler, the awk
 775 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 776 AC_MSG_CHECKING(if big-strings option selected)
 777 AC_ARG_ENABLE(big-strings,
 778         [  --disable-big-strings   assume compiler has only standard-size strings],
 779         [with_big_strings=$enableval],
 780         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 781 AC_MSG_RESULT($with_big_strings)
 782
 783 USE_BIG_STRINGS=0
 784 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
 785 AC_SUBST(USE_BIG_STRINGS)
 786
 787 ###     use option --enable-termcap to compile in the termcap fallback support
 788 AC_MSG_CHECKING(if you want termcap-fallback support)
 789 AC_ARG_ENABLE(termcap,
 790         [  --enable-termcap        compile in termcap fallback support],
 791         [with_termcap=$enableval],
 792         [with_termcap=no])
 793 AC_MSG_RESULT($with_termcap)
 794
 795 NCURSES_USE_TERMCAP=0
 796 if test "x$with_termcap" != "xyes" ; then
 797         if test "$use_database" = no ; then
 798                 if test -z "$with_fallback" ; then
 799                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 800                 fi
 801         fi
 802         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
 803 else
 804
 805         if test "$with_ticlib" != no ; then
 806                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 807         fi
 808
 809         NCURSES_USE_TERMCAP=1
 810         AC_MSG_CHECKING(for list of termcap files)
 811         CF_WITH_PATHLIST(termpath,
 812                 [  --with-termpath=XXX     specify list of termcap files],
 813                 TERMPATH,
 814                 /etc/termcap:/usr/share/misc/termcap)
 815         AC_MSG_RESULT($TERMPATH)
 816         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
 817
 818         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 819         AC_MSG_CHECKING(if fast termcap-loader is needed)
 820         AC_ARG_ENABLE(getcap,
 821                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 822                 [with_getcap=$enableval],
 823                 [with_getcap=no])
 824         AC_MSG_RESULT($with_getcap)
 825         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
 826
 827         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 828         AC_ARG_ENABLE(getcap-cache,
 829                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 830                 [with_getcap_cache=$enableval],
 831                 [with_getcap_cache=no])
 832         AC_MSG_RESULT($with_getcap_cache)
 833         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
 834
 835 fi
 836 AC_SUBST(NCURSES_USE_TERMCAP)
 837
 838 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 839 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 840 AC_ARG_ENABLE(home-terminfo,
 841         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 842         [with_home_terminfo=$enableval],
 843         [with_home_terminfo=yes])
 844 AC_MSG_RESULT($with_home_terminfo)
 845 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
 846
 847 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 848 AC_ARG_ENABLE(root-environ,
 849         [  --disable-root-environ  restrict environment when running as root],
 850         [with_root_environ=$enableval],
 851         [with_root_environ=yes])
 852 AC_MSG_RESULT($with_root_environ)
 853 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
 854
 855 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 856 ###   to reduce storage requirements for the terminfo database.
 857 CF_LINK_FUNCS
 858
 859 with_links=no
 860 with_symlinks=no
 861
 862 # soft links (symbolic links) are useful for some systems where hard links do
 863 # not work, or to make it simpler to copy terminfo trees around.
 864 if test "x$ac_cv_func_symlink" = xyes ; then
 865         AC_MSG_CHECKING(if tic should use symbolic links)
 866         AC_ARG_ENABLE(symlinks,
 867         [  --enable-symlinks       make tic use symbolic links not hard links],
 868         [with_symlinks=$enableval],
 869         [with_symlinks=no])
 870         AC_MSG_RESULT($with_symlinks)
 871 fi
 872
 873 # If we have hard links and did not choose to use soft links instead, there is
 874 # no reason to make this choice optional - use the hard links.
 875 if test "$with_symlinks" = no ; then
 876         AC_MSG_CHECKING(if tic should use hard links)
 877         if test "x$ac_cv_func_link" = xyes ; then
 878                 with_links=yes
 879         else
 880                 with_links=no
 881         fi
 882         AC_MSG_RESULT($with_links)
 883 fi
 884
 885 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
 886 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
 887
 888 ###   use option --enable-broken-linker to force on use of broken-linker support
 889 CF_ENABLE_BROKEN_LINKER
 890
 891 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 892 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 893 AC_ARG_ENABLE(bsdpad,
 894         [  --enable-bsdpad         recognize BSD-style prefix padding],
 895         [with_bsdpad=$enableval],
 896         [with_bsdpad=no])
 897 AC_MSG_RESULT($with_bsdpad)
 898 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
 899
 900 ###   use option --enable-widec to turn on use of wide-character support
 901 NCURSES_CH_T=chtype
 902 NCURSES_LIBUTF8=0
 903
 904 NEED_WCHAR_H=0
 905 NCURSES_MBSTATE_T=0
 906 NCURSES_WCHAR_T=0
 907 NCURSES_WINT_T=0
 908
 909 # Check to define _XOPEN_SOURCE "automatically"
 910 CPPFLAGS_before_XOPEN="$CPPFLAGS"
 911 CF_XOPEN_SOURCE(600)
 912 CPPFLAGS_after_XOPEN="$CPPFLAGS"
 913
 914 # Work around breakage on OS X
 915 CF_SIGWINCH
 916
 917 # Checks for CODESET support.
 918 AM_LANGINFO_CODESET
 919
 920 # use these variables to work around a defect in gcc's fixincludes.
 921 NCURSES_OK_WCHAR_T=
 922 NCURSES_OK_WINT_T=
 923
 924 AC_MSG_CHECKING(if you want wide-character code)
 925 AC_ARG_ENABLE(widec,
 926         [  --enable-widec          compile with wide-char/UTF-8 code],
 927         [with_widec=$enableval],
 928         [with_widec=no])
 929 AC_MSG_RESULT($with_widec)
 930
 931 NCURSES_WCWIDTH_GRAPHICS=1
 932 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
 933
 934 if test "x$with_widec" = xyes ; then
 935         if test "x$disable_lib_suffixes" = xno ; then
 936                 LIB_SUFFIX="w${LIB_SUFFIX}"
 937         fi
 938         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
 939         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
 940
 941         CF_CHECK_WCHAR_H
 942         CF_CHECK_WCWIDTH_GRAPHICS
 943         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
 944
 945         # with_overwrite=no
 946         NCURSES_CH_T=cchar_t
 947         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 948         if test "x$ac_cv_func_putwc" != xyes ; then
 949                 CF_UTF8_LIB
 950                 if test "$cf_cv_utf8_lib" != no ; then
 951                         NCURSES_LIBUTF8=1
 952                 fi
 953         fi
 954         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 955         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 956         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 957
 958         if test "$NCURSES_MBSTATE_T" != 0; then
 959                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
 960         fi
 961 fi
 962 AC_SUBST(NCURSES_CH_T)
 963 AC_SUBST(NCURSES_LIBUTF8)
 964
 965 AC_SUBST(NEED_WCHAR_H)
 966 AC_SUBST(NCURSES_MBSTATE_T)
 967 AC_SUBST(NCURSES_WCHAR_T)
 968 AC_SUBST(NCURSES_WINT_T)
 969
 970 AC_SUBST(NCURSES_OK_WCHAR_T)
 971 AC_SUBST(NCURSES_OK_WINT_T)
 972
 973 ###   use option --disable-lp64 to allow long chtype
 974 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 975 AC_ARG_ENABLE(lp64,
 976         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 977         [with_lp64=$enableval],
 978         [with_lp64=$cf_dft_with_lp64])
 979 AC_MSG_RESULT($with_lp64)
 980
 981 if test "x$with_lp64" = xyes ; then
 982         cf_cv_enable_lp64=1
 983 else
 984         cf_cv_enable_lp64=0
 985 fi
 986 AC_SUBST(cf_cv_enable_lp64)
 987
 988 CF_LARGEFILE
 989
 990 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 991 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 992 AC_ARG_ENABLE(tparm-varargs,
 993         [  --disable-tparm-varargs compile tparm() without varargs interface],
 994         [with_tparm_varargs=$enableval],
 995         [with_tparm_varargs=yes])
 996 AC_MSG_RESULT($with_tparm_varargs)
 997 NCURSES_TPARM_VARARGS=0
 998 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
 999 AC_SUBST(NCURSES_TPARM_VARARGS)
1000
1001 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
1002 if test "$with_ticlib" != no ; then
1003 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
1004 AC_ARG_ENABLE(tic-depends,
1005         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
1006         [with_tic_depends=$enableval],
1007         [with_tic_depends=yes])
1008 AC_MSG_RESULT($with_tic_depends)
1009 else
1010         with_tic_depends=no
1011 fi
1012
1013 ###   use option --disable-wattr-macros to suppress wattr* macros from curses.h
1014 AC_MSG_CHECKING(if you want to suppress wattr* macros to help with ncurses5/ncurses6 transition)
1015 AC_ARG_ENABLE(wattr-macros,
1016         [  --disable-wattr-macros  suppress wattr* macros to help with ncurses5/ncurses6 transition],
1017         [with_wattr_macros=$enableval],
1018         [with_wattr_macros=yes])
1019 if [[ "x$with_wattr_macros" != xyes ]]; then
1020         NCURSES_WATTR_MACROS=0
1021         AC_MSG_RESULT(yes)
1022 else
1023         NCURSES_WATTR_MACROS=1
1024         AC_MSG_RESULT(no)
1025 fi
1026 AC_SUBST(NCURSES_WATTR_MACROS)
1027
1028 CF_WITH_X11_RGB
1029
1030 ###   use option --with-bool to override bool's type
1031 AC_MSG_CHECKING(for type of bool)
1032 AC_ARG_WITH(bool,
1033         [  --with-bool=TYPE        override fallback type of bool variable],
1034         [NCURSES_BOOL="$withval"],
1035         [NCURSES_BOOL=auto])
1036 AC_MSG_RESULT($NCURSES_BOOL)
1037 AC_SUBST(NCURSES_BOOL)
1038
1039 AC_MSG_CHECKING(for alternate terminal capabilities file)
1040 AC_ARG_WITH(caps,
1041         [  --with-caps=alt         compile with alternate Caps file],
1042         [TERMINFO_CAPS=Caps.$withval],
1043         [TERMINFO_CAPS=Caps])
1044 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
1045 AC_MSG_RESULT($TERMINFO_CAPS)
1046 AC_SUBST(TERMINFO_CAPS)
1047
1048 ###   use option --with-chtype to override chtype's type
1049 AC_MSG_CHECKING(for type of chtype)
1050 AC_ARG_WITH(chtype,
1051         [  --with-chtype=TYPE      override type of chtype],
1052         [NCURSES_CHTYPE="$withval"],
1053         [NCURSES_CHTYPE=$cf_dft_chtype])
1054 AC_MSG_RESULT($NCURSES_CHTYPE)
1055
1056 ###   use option --with-ospeed to override ospeed's type
1057 AC_MSG_CHECKING(for type of ospeed)
1058 AC_ARG_WITH(ospeed,
1059         [  --with-ospeed=TYPE      override type of ospeed variable],
1060         [NCURSES_OSPEED="$withval"],
1061         [NCURSES_OSPEED=short])
1062 AC_MSG_RESULT($NCURSES_OSPEED)
1063 AC_SUBST(NCURSES_OSPEED)
1064
1065 ###   use option --with-mmask-t to override mmask_t's type
1066 AC_MSG_CHECKING(for type of mmask_t)
1067 AC_ARG_WITH(mmask-t,
1068         [  --with-mmask-t=TYPE     override type of mmask_t],
1069         [NCURSES_MMASK_T="$withval"],
1070         [NCURSES_MMASK_T=$cf_dft_mmask_t])
1071 AC_MSG_RESULT($NCURSES_MMASK_T)
1072
1073 ###   use option --with-ccharw-max to override CCHARW_MAX size
1074 AC_MSG_CHECKING(for size CCHARW_MAX)
1075 AC_ARG_WITH(ccharw-max,
1076         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1077         [NCURSES_CCHARW_MAX="$withval"],
1078         [NCURSES_CCHARW_MAX=5])
1079 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1080 AC_SUBST(NCURSES_CCHARW_MAX)
1081
1082 AC_CHECK_SIZEOF([signed char])
1083 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1084         NCURSES_SBOOL="signed char"
1085 else
1086         NCURSES_SBOOL="char"
1087 fi
1088 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1089 AC_ARG_ENABLE(signed-char,
1090         [  --enable-signed-char    compile using signed Boolean's in term.h],
1091         [with_signed_char=$enableval],
1092         [with_signed_char=no])
1093 AC_MSG_RESULT($with_signed_char)
1094 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1095 AC_SUBST(NCURSES_SBOOL)
1096
1097 ###   use option --with-tparm-arg to override tparm's argument type
1098 AC_MSG_CHECKING(for type of tparm args)
1099 AC_ARG_WITH(tparm-arg,
1100         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1101         [NCURSES_TPARM_ARG="$withval"],
1102         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1103 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1104 AC_SUBST(NCURSES_TPARM_ARG)
1105
1106 ### Enable compiling-in rcs id's
1107 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1108 AC_ARG_WITH(rcs-ids,
1109         [  --with-rcs-ids          compile-in RCS identifiers],
1110         [with_rcs_ids=$withval],
1111         [with_rcs_ids=no])
1112 AC_MSG_RESULT($with_rcs_ids)
1113 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1114
1115 ###############################################################################
1116 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1117
1118 ###############################################################################
1119 CF_HELP_MESSAGE(Extensions:)
1120
1121 ### Note that some functions (such as const) are normally disabled anyway.
1122 AC_MSG_CHECKING(if you want to build with function extensions)
1123 AC_ARG_ENABLE(ext-funcs,
1124         [  --disable-ext-funcs     disable function-extensions],
1125         [with_ext_funcs=$enableval],
1126         [with_ext_funcs=yes])
1127 AC_MSG_RESULT($with_ext_funcs)
1128 if test "x$with_ext_funcs" = xyes ; then
1129         NCURSES_EXT_FUNCS=1
1130         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1131         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1132         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1133         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1134         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1135         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1136         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1137         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1138         AC_DEFINE(HAVE_USE_EXTENDED_NAMES,1,[Define to 1 to enable use_extended_names() function in test-programs])
1139         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1140         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1141         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1142         GENERATED_EXT_FUNCS=generated
1143         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1144 else
1145         NCURSES_EXT_FUNCS=0
1146         GENERATED_EXT_FUNCS=
1147 fi
1148 AC_SUBST(NCURSES_EXT_FUNCS)
1149 AC_SUBST(GENERATED_EXT_FUNCS)
1150
1151 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1152 AC_ARG_ENABLE(sp-funcs,
1153         [  --enable-sp-funcs       enable SCREEN-extensions],
1154         [with_sp_funcs=$enableval],
1155         [with_sp_funcs=$cf_dft_ext_spfuncs])
1156 AC_MSG_RESULT($with_sp_funcs)
1157 if test "x$with_sp_funcs" = xyes ; then
1158         NCURSES_SP_FUNCS=1
1159         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1160         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1161         GENERATED_SP_FUNCS=generated
1162 else
1163         NCURSES_SP_FUNCS=0
1164         GENERATED_SP_FUNCS=
1165 fi
1166 AC_SUBST(NCURSES_SP_FUNCS)
1167 AC_SUBST(GENERATED_SP_FUNCS)
1168
1169 AC_MSG_CHECKING(if you want to build with terminal-driver)
1170 AC_ARG_ENABLE(term-driver,
1171         [  --enable-term-driver    enable terminal-driver],
1172         [with_term_driver=$enableval],
1173         [with_term_driver=no])
1174 AC_MSG_RESULT($with_term_driver)
1175 if test "x$with_term_driver" = xyes ; then
1176         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1177         if test "x$with_termlib" != xno ; then
1178                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1179         fi
1180         if test "x$with_sp_funcs" != xyes ; then
1181                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1182         fi
1183 fi
1184
1185 ###   use option --enable-const to turn on use of const beyond that in XSI.
1186 AC_MSG_CHECKING(for extended use of const keyword)
1187 AC_ARG_ENABLE(const,
1188         [  --enable-const          compile with extra/non-standard const],
1189         [with_ext_const=$enableval],
1190         [with_ext_const=$cf_dft_ext_const])
1191 AC_MSG_RESULT($with_ext_const)
1192 NCURSES_CONST='/*nothing*/'
1193 if test "x$with_ext_const" = xyes ; then
1194         NCURSES_CONST=const
1195 fi
1196 AC_SUBST(NCURSES_CONST)
1197
1198 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1199 AC_MSG_CHECKING(if you want to use extended colors)
1200 AC_ARG_ENABLE(ext-colors,
1201         [  --enable-ext-colors     compile for 256-color support],
1202         [with_ext_colors=$enableval],
1203         [with_ext_colors=$cf_dft_ext_colors])
1204 AC_MSG_RESULT($with_ext_colors)
1205 NCURSES_EXT_COLORS=0
1206 if test "x$with_ext_colors" = xyes ; then
1207         if test "x$with_widec" != xyes ; then
1208                 AC_MSG_WARN(This option applies only to wide-character library)
1209         else
1210                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1211                 CF_NCURSES_ABI_6
1212                 NCURSES_EXT_COLORS=1
1213                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1214                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1215                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1216                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1217         fi
1218 fi
1219 AC_SUBST(NCURSES_EXT_COLORS)
1220
1221 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1222 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1223 AC_ARG_ENABLE(ext-mouse,
1224         [  --enable-ext-mouse      compile for extended mouse-encoding],
1225         [with_ext_mouse=$enableval],
1226         [with_ext_mouse=$cf_dft_ext_mouse])
1227 AC_MSG_RESULT($with_ext_mouse)
1228 NCURSES_MOUSE_VERSION=1
1229 if test "x$with_ext_mouse" = xyes ; then
1230         NCURSES_MOUSE_VERSION=2
1231         CF_NCURSES_ABI_6
1232 fi
1233 AC_SUBST(NCURSES_MOUSE_VERSION)
1234
1235 ###   use option --enable-ext-putwin to turn on extended screendumps
1236 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1237 AC_ARG_ENABLE(ext-putwin,
1238         [  --enable-ext-putwin     compile with extended putwin/screendump],
1239         [with_ext_putwin=$enableval],
1240         [with_ext_putwin=$cf_dft_ext_putwin])
1241 AC_MSG_RESULT($with_ext_putwin)
1242 if test "x$with_ext_putwin" = xyes ; then
1243         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1244 fi
1245
1246 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1247 AC_ARG_ENABLE(no-padding,
1248         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1249         [with_no_padding=$enableval],
1250         [with_no_padding=$with_ext_funcs])
1251 AC_MSG_RESULT($with_no_padding)
1252 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1253
1254 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1255 AC_MSG_CHECKING(if you want SIGWINCH handler)
1256 AC_ARG_ENABLE(sigwinch,
1257         [  --enable-sigwinch       compile with SIGWINCH handler],
1258         [with_sigwinch=$enableval],
1259         [with_sigwinch=$with_ext_funcs])
1260 AC_MSG_RESULT($with_sigwinch)
1261 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1262
1263 ###   use option --enable-tcap-names to allow user to define new capabilities
1264 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1265 AC_ARG_ENABLE(tcap-names,
1266         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1267         [with_tcap_names=$enableval],
1268         [with_tcap_names=$with_ext_funcs])
1269 AC_MSG_RESULT($with_tcap_names)
1270 NCURSES_XNAMES=0
1271 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1272 AC_SUBST(NCURSES_XNAMES)
1273
1274 ##############################################################################
1275 CF_HELP_MESSAGE(Reentrant Code:)
1276 CF_WITH_PTHREAD
1277
1278 if test "x$with_pthread" != xno; then
1279         AC_CHECK_FUNC(pthread_kill,[
1280                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1281                 AC_ARG_ENABLE(pthreads-eintr,
1282                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1283                         [use_pthreads_eintr=$enableval],
1284                         [use_pthreads_eintr=no])
1285                 AC_MSG_RESULT($use_pthreads_eintr)
1286                 if test "x$use_pthreads_eintr" = xyes ; then
1287                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1288                 fi])
1289
1290         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1291         AC_ARG_ENABLE(weak-symbols,
1292                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1293                 [use_weak_symbols=$enableval],
1294                 [use_weak_symbols=no])
1295         AC_MSG_RESULT($use_weak_symbols)
1296         if test "x$use_weak_symbols" = xyes ; then
1297                 CF_WEAK_SYMBOLS
1298         else
1299                 cf_cv_weak_symbols=no
1300         fi
1301
1302         if test "x$cf_cv_weak_symbols" = xyes ; then
1303                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1304         fi
1305 fi
1306
1307 PTHREAD=
1308 if test "x$with_pthread" = "xyes" ; then
1309         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1310         enable_reentrant=yes
1311         if test "x$cf_cv_weak_symbols" = xyes ; then
1312                 PTHREAD=-lpthread
1313                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1314         fi
1315 fi
1316 AC_SUBST(PTHREAD)
1317
1318 # Reentrant code has to be opaque; there's little advantage to making ncurses
1319 # opaque outside of that, so there is no --enable-opaque option.  We can use
1320 # this option without --with-pthreads, but this will be always set for
1321 # pthreads.
1322 AC_MSG_CHECKING(if you want reentrant code)
1323 AC_ARG_ENABLE(reentrant,
1324         [  --enable-reentrant      compile with reentrant code],
1325         [with_reentrant=$enableval],
1326         [with_reentrant=no])
1327 AC_MSG_RESULT($with_reentrant)
1328 if test "x$with_reentrant" = xyes ; then
1329         cf_cv_enable_reentrant=1
1330         cf_cv_enable_opaque="NCURSES_INTERNALS"
1331         NCURSES_SIZE_T=int
1332         if test "x$cf_cv_weak_symbols" = xyes ; then
1333                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1334                 CF_ADD_LIB(pthread,TEST_LIBS)
1335                 CF_ADD_LIB(pthread,TEST_LIBS2)
1336                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1337         else
1338                 # when not using weak symbols but with_reentrant,
1339                 # add 't' to the library suffix on all platforms
1340                 # except cygwin, where we only do that if ALSO
1341                 # compiling with full thread support.
1342                 case "$host" in
1343                 (*cygwin* | *msys*)
1344                         if test "$with_pthread" = "yes" ; then
1345                                 if test "x$disable_lib_suffixes" = "xno" ; then
1346                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1347                                 fi
1348                         fi ;;
1349                 (*)
1350                         if test "x$disable_lib_suffixes" = "xno" ; then
1351                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1352                         fi
1353                         ;;
1354                 esac
1355         fi
1356         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1357         CF_NCURSES_ABI_6
1358 else
1359         cf_cv_enable_reentrant=0
1360         cf_cv_enable_opaque="NCURSES_OPAQUE"
1361         NCURSES_SIZE_T=short
1362 fi
1363 AC_SUBST(cf_cv_enable_reentrant)
1364 AC_SUBST(cf_cv_enable_opaque)
1365
1366 AC_SUBST(NCURSES_SIZE_T)
1367
1368 AC_MSG_CHECKING(if you want opaque curses-library structures)
1369 CF_ARG_ENABLE(opaque-curses,
1370         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1371         [enable_opaque_curses=yes],[
1372          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1373          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=no
1374         ])
1375 AC_MSG_RESULT($enable_opaque_curses)
1376
1377 test "$cf_cv_enable_reentrant" = 1 && \
1378 test "$enable_opaque_curses" = no && \
1379 AC_MSG_ERROR(reentrant configuration requires opaque library)
1380
1381 AC_MSG_CHECKING(if you want opaque form-library structures)
1382 AC_ARG_ENABLE(opaque-form,
1383         [  --enable-opaque-form    make form-library structures "opaque"],
1384         [enable_opaque_form=yes],[enable_opaque_form=no])
1385 AC_MSG_RESULT($enable_opaque_form)
1386
1387 AC_MSG_CHECKING(if you want opaque menu-library structures)
1388 AC_ARG_ENABLE(opaque-menu,
1389         [  --enable-opaque-menu    make menu-library structures "opaque"],
1390         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1391 AC_MSG_RESULT($enable_opaque_menu)
1392
1393 AC_MSG_CHECKING(if you want opaque panel-library structures)
1394 AC_ARG_ENABLE(opaque-panel,
1395         [  --enable-opaque-panel   make panel-library structures "opaque"],
1396         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1397 AC_MSG_RESULT($enable_opaque_panel)
1398
1399 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1400 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1401 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1402 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1403
1404 AC_SUBST(NCURSES_OPAQUE)
1405 AC_SUBST(NCURSES_OPAQUE_FORM)
1406 AC_SUBST(NCURSES_OPAQUE_MENU)
1407 AC_SUBST(NCURSES_OPAQUE_PANEL)
1408
1409 ### Allow using a different wrap-prefix
1410 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1411         AC_MSG_CHECKING(for prefix used to wrap public variables)
1412         AC_ARG_WITH(wrap-prefix,
1413                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1414                 [NCURSES_WRAP_PREFIX=$withval],
1415                 [NCURSES_WRAP_PREFIX=_nc_])
1416         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1417 else
1418         NCURSES_WRAP_PREFIX=_nc_
1419 fi
1420 AC_SUBST(NCURSES_WRAP_PREFIX)
1421 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1422
1423 ###############################################################################
1424 # These options are relatively safe to experiment with.
1425 CF_HELP_MESSAGE(Development Code:)
1426 AC_MSG_CHECKING(if you want all development code)
1427 AC_ARG_WITH(develop,
1428         [  --without-develop       disable development options],
1429         [with_develop=$withval],
1430         [with_develop=no])
1431 AC_MSG_RESULT($with_develop)
1432
1433 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1434 AC_MSG_CHECKING(if you want hard-tabs code)
1435 AC_ARG_ENABLE(hard-tabs,
1436         [  --enable-hard-tabs      compile with hard-tabs code],,
1437         [enable_hard_tabs=$with_develop])
1438 AC_MSG_RESULT($enable_hard_tabs)
1439 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1440
1441 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1442 AC_MSG_CHECKING(if you want limited support for xmc)
1443 AC_ARG_ENABLE(xmc-glitch,
1444         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1445         [enable_xmc_glitch=$with_develop])
1446 AC_MSG_RESULT($enable_xmc_glitch)
1447 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1448
1449 ###############################################################################
1450 # These are just experimental, probably should not be in a package:
1451 CF_HELP_MESSAGE(Experimental Code:)
1452
1453 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1454 AC_ARG_ENABLE(assumed-color,
1455         [  --disable-assumed-color do not assume anything about default-colors],
1456         [with_assumed_color=$enableval],
1457         [with_assumed_color=yes])
1458 AC_MSG_RESULT($with_assumed_color)
1459 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1460
1461 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1462 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1463 AC_ARG_ENABLE(hashmap,
1464         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1465         [with_hashmap=$enableval],
1466         [with_hashmap=yes])
1467 AC_MSG_RESULT($with_hashmap)
1468 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1469
1470 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1471 AC_MSG_CHECKING(if you want colorfgbg code)
1472 AC_ARG_ENABLE(colorfgbg,
1473         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1474         [with_colorfgbg=$enableval],
1475         [with_colorfgbg=no])
1476 AC_MSG_RESULT($with_colorfgbg)
1477 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1478
1479 ###   use option --enable-fvisibility to turn on use of gcc-specific feature
1480 AC_MSG_CHECKING(if you want to use gcc -fvisibility option)
1481 AC_ARG_ENABLE(fvisibility,
1482         [  --enable-fvisibility    compile with -fvisibility=hidden],
1483         [cf_with_fvisibility=$enableval],
1484         [cf_with_fvisibility=no])
1485 AC_MSG_RESULT($cf_with_fvisibility)
1486
1487 NCURSES_IMPEXP=
1488 NCURSES_CXX_IMPEXP=
1489 if test "x$cf_with_fvisibility" = xyes; then
1490         CF_CHECK_FVISIBILITY($CC,CFLAGS,cf_cv_fvisibility_hidden)
1491         if test "x$cf_cv_fvisibility_hidden" = xyes
1492         then
1493                 CF_ADD_CFLAGS([-fvisibility=hidden])
1494                 NCURSES_IMPEXP="__attribute__ ((visibility(\"default\")))"
1495         fi
1496         if test -n "$CXX"
1497         then
1498                 AC_LANG_PUSH(C++)
1499                 CF_CHECK_FVISIBILITY($CXX,CXXFLAGS,cf_cv_fvisibility_hidden2)
1500                 if test "x$cf_cv_fvisibility_hidden2" = xyes
1501                 then
1502                         CF_ADD_CXXFLAGS([-fvisibility=hidden])
1503                         NCURSES_CXX_IMPEXP="__attribute__ ((visibility(\"default\")))"
1504                 fi
1505                 AC_LANG_POP
1506         fi
1507 fi
1508 AC_SUBST(NCURSES_IMPEXP)
1509 AC_SUBST(NCURSES_CXX_IMPEXP)
1510
1511 ###   use option --enable-interop to turn on use of bindings used for interop
1512 AC_MSG_CHECKING(if you want interop bindings)
1513 AC_ARG_ENABLE(interop,
1514         [  --enable-interop        compile-in interop bindings],
1515         [with_exp_interop=$enableval],
1516         [with_exp_interop=$cf_dft_interop])
1517 AC_MSG_RESULT($with_exp_interop)
1518
1519 NCURSES_INTEROP_FUNCS=0
1520 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1521 AC_SUBST(NCURSES_INTEROP_FUNCS)
1522
1523
1524 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1525 AC_ARG_ENABLE(safe-sprintf,
1526         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1527         [with_safe_sprintf=$enableval],
1528         [with_safe_sprintf=no])
1529 AC_MSG_RESULT($with_safe_sprintf)
1530
1531 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1532 # when hashmap is used scroll hints are useless
1533 if test "$with_hashmap" = no ; then
1534 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1535 AC_ARG_ENABLE(scroll-hints,
1536         [  --disable-scroll-hints  compile without scroll-hints code],
1537         [with_scroll_hints=$enableval],
1538         [with_scroll_hints=yes])
1539 AC_MSG_RESULT($with_scroll_hints)
1540 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1541 fi
1542
1543 AC_MSG_CHECKING(if you want wgetch-events code)
1544 AC_ARG_ENABLE(wgetch-events,
1545         [  --enable-wgetch-events  compile with wgetch-events code],
1546         [with_wgetch_events=$enableval],
1547         [with_wgetch_events=no])
1548 AC_MSG_RESULT($with_wgetch_events)
1549 if test "x$with_wgetch_events" = xyes ; then
1550         AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1551         NCURSES_WGETCH_EVENTS=1
1552 else
1553         NCURSES_WGETCH_EVENTS=0
1554 fi
1555 AC_SUBST(NCURSES_WGETCH_EVENTS)
1556
1557 case "$cf_cv_system_name" in
1558 (*mingw32*|*mingw64*|*-msvc*)
1559         AC_MSG_CHECKING(if you want experimental-Windows driver)
1560         AC_ARG_ENABLE(exp-win32,
1561                 [  --enable-exp-win32      compile with experimental-Windows driver],
1562                 [with_exp_win32=$enableval],
1563                 [with_exp_win32=no])
1564         AC_MSG_RESULT($with_exp_win32)
1565         if test "x$with_exp_win32" = xyes
1566         then
1567                 AC_DEFINE(EXP_WIN32_DRIVER,1,[Define to 1 to compile with experimental win32 driver])
1568                 EXP_WIN32_DRIVER=1
1569                 INTERNALS_HDR='[$](INCDIR)/nc_win32.h'
1570         else
1571                 INTERNALS_HDR='[$](INCDIR)/nc_mingw.h'
1572                 EXP_WIN32_DRIVER=0
1573         fi
1574         ;;
1575 (*)
1576         EXP_WIN32_DRIVER=0
1577         INTERNALS_HDR=
1578         ;;
1579 esac
1580 AC_SUBST(EXP_WIN32_DRIVER)
1581 AC_SUBST(INTERNALS_HDR)
1582
1583 ###############################################################################
1584 CF_HELP_MESSAGE(Testing/development Options:)
1585
1586 ###     use option --disable-echo to suppress full display compiling commands
1587 CF_DISABLE_ECHO
1588 if test "x$enable_echo" = xyes; then
1589         ECHO_LINK=
1590 else
1591         ECHO_LINK='@ echo linking $@ ... ;'
1592         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1593         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1594 fi
1595 AC_SUBST(ECHO_LINK)
1596
1597 # --disable-stripping is used for debugging
1598 CF_INSTALL_OPTS
1599
1600 # If we're avoiding relinking of shared libraries during install, that is to
1601 # avoid modifying the build-tree.  For the same reason, avoid doing ranlib if
1602 # the install program has "-p" (for preserving timestamps).
1603 cf_cv_do_reranlib=yes
1604 if test "x$cf_cv_install_p" = xyes
1605 then
1606         if test "x$cf_cv_do_relink" != xyes
1607         then
1608                 cf_cv_do_reranlib=no
1609                 INSTALL_OPT_P="-p"
1610                 INSTALL_LIB="$INSTALL_LIB $INSTALL_OPT_P"
1611         fi
1612 fi
1613 AC_SUBST(INSTALL_OPT_P)
1614
1615 ###     use option --enable-warnings to turn on all gcc warnings
1616 CF_ENABLE_WARNINGS(Wno-unknown-pragmas Wswitch-enum,yes)
1617
1618 if test "x$enable_warnings" = "xyes"; then
1619         CF_ADD_ADAFLAGS(-gnatg)
1620         if test "x$cf_with_cxx" = xyes ; then
1621                 CF_GXX_WARNINGS(Wno-unused)
1622         fi
1623 fi
1624 CF_ENABLE_STRING_HACKS
1625
1626 ###     use option --enable-assertions to turn on generation of assertion code
1627 AC_MSG_CHECKING(if you want to enable runtime assertions)
1628 AC_ARG_ENABLE(assertions,
1629         [  --enable-assertions     test: turn on generation of assertion code],
1630         [with_assertions=$enableval],
1631         [with_assertions=no])
1632 AC_MSG_RESULT($with_assertions)
1633 if test -n "$GCC"
1634 then
1635         if test "$with_assertions" = no
1636         then
1637                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1638         else
1639                 CF_ADD_ADAFLAGS(-gnata)
1640         fi
1641 fi
1642
1643 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1644 CF_DISABLE_LEAKS
1645 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1646
1647 ###     use option --enable-expanded to generate certain macros as functions
1648 AC_ARG_ENABLE(expanded,
1649         [  --enable-expanded       test: generate functions for certain macros],
1650         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1651
1652 ###     use option --disable-macros to suppress macros in favor of functions
1653 AC_ARG_ENABLE(macros,
1654         [  --disable-macros        test: use functions rather than macros],
1655         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1656
1657 # Normally we only add trace() to the debug-library.  Allow this to be
1658 # extended to all models of the ncurses library:
1659 cf_all_traces=no
1660 case "$CFLAGS $CPPFLAGS" in
1661 (*-DTRACE*)
1662         cf_all_traces=yes
1663         ;;
1664 esac
1665
1666 AC_MSG_CHECKING(whether to add trace feature to all models)
1667 AC_ARG_WITH(trace,
1668 [  --with-trace            test: add trace() function to all models of ncurses],
1669 [cf_with_trace=$withval],
1670 [cf_with_trace=$cf_all_traces])
1671 AC_MSG_RESULT($cf_with_trace)
1672
1673 if test "x$cf_with_trace" = xyes ; then
1674         LIB_TRACING=all
1675         ADA_TRACE=TRUE
1676         CF_ADD_CFLAGS(-DTRACE)
1677         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1678 else
1679         LIB_TRACING=DEBUG
1680         ADA_TRACE=FALSE
1681 fi
1682
1683 AC_SUBST(ADA_TRACE)
1684
1685 CF_DISABLE_GNAT_PROJECTS
1686
1687 ###     Checks for libraries.
1688 case "$cf_cv_system_name" in
1689 (*mingw32*|*mingw64*)
1690         if test "x$with_exp_win32" = xyes ; then
1691         CPPFLAGS="$CPPFLAGS -DWINVER=0x0600 -DWIN32_LEAN_AND_MEAN"
1692         else
1693         CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1694         fi
1695         # Note: WINVER may be a problem with Windows 10
1696         ;;
1697 (*)
1698 AC_CHECK_FUNC(gettimeofday,
1699         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1700
1701 AC_CHECK_LIB(bsd, gettimeofday,
1702         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1703         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1704         ;;
1705 esac
1706
1707 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1708 AC_SUBST(MATH_LIB)
1709
1710 ###     Checks for header files.
1711 AC_STDC_HEADERS
1712 AC_HEADER_DIRENT
1713 AC_HEADER_TIME
1714 CF_REGEX
1715
1716 dnl These are some other potentially nonportable headers.
1717 AC_CHECK_HEADERS( \
1718 fcntl.h \
1719 getopt.h \
1720 limits.h \
1721 locale.h \
1722 math.h \
1723 poll.h \
1724 sys/ioctl.h \
1725 sys/param.h \
1726 sys/poll.h \
1727 sys/select.h \
1728 sys/time.h \
1729 sys/times.h \
1730 ttyent.h \
1731 unistd.h \
1732 wctype.h \
1733 )
1734
1735 CF_GETOPT_HEADER
1736
1737 CF_CHECK_ENVIRON(environ)
1738 CF_CHECK_GETENV
1739 if test "x$cf_cv_consistent_getenv" = xno && \
1740         test "x$cf_with_trace" = xyes
1741 then
1742         AC_MSG_WARN(The NCURSES_TRACE environment variable is not supported with this configuration)
1743 fi
1744
1745 CF_SYS_TIME_SELECT
1746
1747 ###     checks for compiler characteristics
1748 AC_LANG_C
1749 AC_C_CONST
1750 CF_C_INLINE(NCURSES_INLINE,1200)
1751 CF_SIG_ATOMIC_T
1752
1753 if test "$NCURSES_CHTYPE" = auto ; then
1754         CF_TYPEOF_CHTYPE
1755 else
1756         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1757 fi
1758 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1759 AC_SUBST(cf_cv_typeof_chtype)
1760
1761 CF_UNSIGNED_LITERALS
1762 cf_cv_1UL="1"
1763 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1764 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1765 AC_SUBST(cf_cv_1UL)
1766
1767 if test "$NCURSES_MMASK_T" = auto ; then
1768         cf_cv_typeof_mmask_t=long
1769 else
1770         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1771 fi
1772 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1773 AC_SUBST(cf_cv_typeof_mmask_t)
1774
1775 ###     Checks for external-data
1776 CF_ERRNO
1777 CF_LINK_DATAONLY
1778
1779 ###     Checks for library functions.
1780 AC_CHECK_FUNCS( \
1781 getcwd \
1782 getegid \
1783 geteuid \
1784 getopt \
1785 getttynam \
1786 issetugid \
1787 localeconv \
1788 poll \
1789 putenv \
1790 remove \
1791 select \
1792 setbuf \
1793 setbuffer \
1794 setenv \
1795 setvbuf \
1796 sigaction \
1797 sigvec \
1798 snprintf \
1799 strdup \
1800 strstr \
1801 sysconf \
1802 tcgetpgrp \
1803 times \
1804 tsearch \
1805 vsnprintf \
1806 )
1807
1808 if test "x$ac_cv_func_getopt" = xno && \
1809    test "x$cf_with_progs$cf_with_tests" != xnono; then
1810         AC_MSG_ERROR(getopt is required for building programs)
1811 fi
1812
1813 if test "x$with_safe_sprintf" = xyes
1814 then
1815         if test "x$ac_cv_func_vsnprintf" = xyes
1816         then
1817                 AC_MSG_WARN(will use vsnprintf instead of safe-sprintf option)
1818         else
1819                 AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1820         fi
1821 fi
1822
1823 if test "x$with_getcap" = "xyes" ; then
1824         CF_CGETENT
1825 fi
1826
1827 CF_ISASCII
1828 CF_STRUCT_SIGACTION
1829 CF_FUNC_NANOSLEEP
1830 CF_FUNC_TERMIOS
1831 CF_FUNC_VSSCANF
1832 CF_MKSTEMP
1833
1834 # setup for prototype of fallback for vsscanf()
1835 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1836
1837 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1838 if test "x$cross_compiling" = xyes ; then
1839         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1840 else
1841         AC_FUNC_SETVBUF_REVERSED
1842 fi
1843 AC_CHECK_TYPE(intptr_t, long)
1844 AC_CHECK_TYPE(ssize_t, int)
1845 CF_TYPE_SIGACTION
1846 CF_SIZECHANGE
1847 CF_FUNC_MEMMOVE
1848 CF_FUNC_POLL
1849 CF_VA_COPY
1850 AC_FUNC_VFORK
1851 CF_FOPEN_BIN_R
1852
1853 # special check for test/ditto.c
1854 CF_FUNC_OPENPTY
1855 if test "$cf_cv_func_openpty" != no ; then
1856         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1857         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1858         if test "x$cf_cv_lib_util" = xyes ; then
1859                 CF_ADD_LIB(util,TEST_LIBS)
1860         fi
1861 fi
1862 AC_SUBST(TEST_LIBS)
1863 AC_SUBST(TEST_LIBS2)
1864
1865 if test "$with_hashed_db" != no ; then
1866         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1867         CF_HASHED_DB($with_hashed_db)
1868 fi
1869
1870 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1871 if test -z "$cf_user_CFLAGS" && test "$enable_leaks" = yes ; then
1872         CF_STRIP_G_OPT(CFLAGS)
1873         CF_STRIP_G_OPT(CXXFLAGS)
1874 fi
1875
1876 # Just in case, check if the C compiler has a bool type.
1877 CF_BOOL_DECL(cf_cv_cc_bool_type)
1878
1879 # Check for C++ compiler characteristics (and ensure that it's there!)
1880 if test -n "$CXX" ; then
1881         AC_LANG_CPLUSPLUS
1882         CF_STDCPP_LIBRARY
1883         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1884
1885         case "$GXX_VERSION" in
1886         (1.*|2.[[0-6]]*|[[1-9]][[0-9]].*)
1887                 cf_cxx_library=yes
1888                 ;;
1889         (*-2.7*|2.7*)
1890                 CF_GPP_LIBRARY
1891                 ;;
1892         (*)
1893                 cf_cxx_library=no
1894                 ;;
1895         esac
1896
1897         AC_CHECK_HEADERS(typeinfo)
1898         CF_CXX_IOSTREAM_NAMESPACE
1899         CF_BOOL_DECL
1900         CF_BOOL_SIZE
1901         CF_ETIP_DEFINES
1902         CF_CPP_PARAM_INIT
1903         CF_CPP_STATIC_CAST
1904         CF_CXX_AR_FLAGS
1905 else
1906         cf_cxx_library=no
1907         cf_cv_builtin_bool=1
1908
1909         # Just because we are not configuring against C++ right now does not
1910         # mean that a user will not want to use C++.  Some distributors disable
1911         # the C++ portion of this configuration as a shortcut (or just to avoid
1912         # compiling the demo in the c++ directory).  So we need a reasonable
1913         # default for the 'bool' type.
1914         #
1915         # Caveat: since the storage of the bool type is not standardized, it
1916         # may change.
1917
1918         if test "$NCURSES_BOOL" != auto ; then
1919                 cf_cv_type_of_bool=$NCURSES_BOOL
1920                 cf_cv_header_stdbool_h=0
1921         else
1922                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1923                         CF_BOOL_SIZE
1924                 else
1925                         AC_MSG_CHECKING(for fallback type of bool)
1926                         case "$host_cpu" in
1927                         (i?86)  cf_cv_type_of_bool=char ;;
1928                         (*)     cf_cv_type_of_bool=int  ;;
1929                         esac
1930                         AC_MSG_RESULT($cf_cv_type_of_bool)
1931                 fi
1932         fi
1933 fi
1934 AC_SUBST(CXXLIBS)
1935
1936 # If the C compiler did not declare bool, and we did not determine that the C++
1937 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1938 # ncurses library use the same type as C++ bool.  Note that this allows one to
1939 # specify the type of bool in a configure-script option and postpone
1940 # integration with the C++ compiler provided that the types are compatible.
1941 USE_CXX_BOOL=1
1942 if test "$cf_cv_cc_bool_type" = 1
1943 then
1944         # oops: C has a bool.  Unlikely, but C++ could differ.
1945         USE_CXX_BOOL=0
1946 elif test "$cf_cv_builtin_bool" = 0
1947 then
1948         # C++ has no bool
1949         USE_CXX_BOOL=0
1950 else
1951         # this is the normal case
1952         USE_CXX_BOOL='defined(__cplusplus)'
1953 fi
1954 AC_SUBST(USE_CXX_BOOL)
1955
1956 CF_HELP_MESSAGE(Ada Binding Options:)
1957
1958 dnl If the Ada95 source-tree is present, add that to the build unless it will
1959 dnl not work, or was not requested.
1960 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1961
1962 dnl libtool does not know anything about GNAT, though a change made in 1998
1963 dnl provided for it "someday".  Disable the ada subtree if we are using
1964 dnl libtool -TD 20070714
1965         if test "$cf_with_ada" != "no" ; then
1966                 if test "$with_libtool" != "no"; then
1967                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1968                         cf_with_ada=no
1969                 fi
1970         fi
1971
1972 dnl Check for availability of GNU Ada Translator (GNAT).
1973 dnl At the moment we support no other Ada compiler.
1974         if test "$cf_with_ada" != "no" ; then
1975                 CF_PROG_GNAT
1976                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1977                         CF_ADD_ADAFLAGS(-gnatpn)
1978                         CF_FIXUP_ADAFLAGS
1979
1980                         CF_GNATPREP_OPT_T
1981
1982                         CF_GNAT_GENERICS
1983                         CF_GNAT_SIGINT
1984                         CF_GNAT_PROJECTS
1985
1986                         CF_WITH_ADA_COMPILER
1987
1988                         cf_ada_package=terminal_interface
1989                         AC_SUBST(cf_ada_package)
1990
1991                         CF_WITH_ADA_INCLUDE
1992                         CF_WITH_ADA_OBJECTS
1993                         CF_WITH_ADA_SHAREDLIB
1994
1995                         # allow the Ada binding to be renamed
1996                         CF_WITH_ADA_LIBNAME(AdaCurses)
1997                 fi
1998         fi
1999 else
2000         cf_with_ada=no
2001 fi
2002
2003 # do this "late" to avoid conflict with header-checks
2004 if test "x$with_widec" = xyes ; then
2005         AC_CHECK_SIZEOF(wchar_t)
2006         # cross-compiling to mingw can run into the problem that attempting to
2007         # link with the regex library fails, causing the test to not set this to
2008         # a number.  "recent" autoconf does not address this problem either -TD
2009         if test -z "$ac_cv_sizeof_wchar_t"
2010         then
2011                 CF_VERBOSE(test failed (assume 2))
2012                 sed /SIZEOF_WCHAR_T/d confdefs.h >confdefs.tmp
2013                 mv confdefs.tmp confdefs.h
2014                 echo "#define SIZEOF_WCHAR_T 2" >>confdefs.h
2015         fi
2016 fi
2017
2018 ### Construct the ncurses library-subsets, if any, from this set of keywords:
2019 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
2020 ###
2021 ### ticlib modules may be a separate library, otherwise contained in termlib.
2022 ### termlib modules may be a separate library, otherwise contained in ncurses.
2023 ###
2024 ### The of "+" or " " between the tokens controls the way the script
2025 ### chooses to split module lists into libraries.
2026 ###
2027 ### (see CF_LIB_RULES).
2028 AC_MSG_CHECKING(for library subsets)
2029 LIB_SUBSETS=
2030
2031 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
2032         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
2033         if test "$with_ticlib" != no ; then
2034                 LIB_SUBSETS="${LIB_SUBSETS} "
2035         else
2036                 LIB_SUBSETS="${LIB_SUBSETS}+"
2037         fi
2038 fi
2039
2040 LIB_SUBSETS="${LIB_SUBSETS}termlib"
2041 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
2042
2043 if test "$with_termlib" != no ; then
2044         LIB_SUBSETS="${LIB_SUBSETS} "
2045 else
2046         LIB_SUBSETS="${LIB_SUBSETS}+"
2047 fi
2048
2049 LIB_SUBSETS="${LIB_SUBSETS}base"
2050
2051 # Most term-driver calls are to tinfo, but some like init_pair are to the
2052 # base library (so it resides in base).
2053 if test "$with_term_driver" != no ; then
2054         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
2055         case "$cf_cv_system_name" in
2056         (*mingw32*|*mingw64*)
2057                 if test "x$with_exp_win32" = xyes ; then
2058                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32"
2059                 else
2060                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
2061                 fi
2062                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
2063                 ;;
2064         (*)
2065                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
2066                 ;;
2067         esac
2068 elif test "x$with_exp_win32" = xyes ; then
2069         case "$cf_cv_system_name" in
2070         (*mingw32*|*mingw64*)
2071                 LIB_SUBSETS="${LIB_SUBSETS}+port_win32"
2072                 ;;
2073         (*)
2074                 ;;
2075         esac
2076 fi
2077
2078 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
2079 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
2080
2081 AC_MSG_RESULT($LIB_SUBSETS)
2082
2083 ### Construct the list of include-directories to be generated
2084 CF_INCLUDE_DIRS
2085 CF_ADA_INCLUDE_DIRS
2086
2087 ### Build up pieces for makefile rules
2088 AC_MSG_CHECKING(default library suffix)
2089 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
2090 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
2091 AC_MSG_RESULT($DFT_ARG_SUFFIX)
2092
2093 AC_MSG_CHECKING(default library-dependency suffix)
2094 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
2095 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
2096 AC_MSG_RESULT($DFT_DEP_SUFFIX)
2097
2098 AC_MSG_CHECKING(default object directory)
2099 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
2100 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
2101 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
2102
2103 if test "x$cf_with_cxx" = xyes ; then
2104 AC_MSG_CHECKING(c++ library-dependency suffix)
2105 if test "$with_libtool" != "no"; then
2106         # libtool thinks it can make c++ shared libraries (perhaps only g++)
2107         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2108 elif test "$with_shared_cxx" != "no"; then
2109         # also for g++ users...
2110         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2111 else
2112         # we normally make a static library because C/C++ library rules differ
2113         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
2114 fi
2115 AC_MSG_RESULT($CXX_LIB_SUFFIX)
2116 AC_SUBST(CXX_LIB_SUFFIX)
2117 fi
2118
2119 # do not want -ldl in build except as needed for -lncurses dependency
2120 if test "x$with_dlsym" = xyes ; then
2121 if test "$DFT_LWR_MODEL" = shared || \
2122    test "$DFT_LWR_MODEL" = libtool ; then
2123         CF_REMOVE_LIB(LIBS,$LIBS,dl)
2124 fi
2125 fi
2126 ### Set up low-level terminfo dependencies for makefiles.
2127
2128 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
2129 # do not need libdl
2130 TICS_LIST=
2131 if test "x$with_dlsym" = xyes ; then
2132         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
2133 fi
2134
2135 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
2136 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
2137 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
2138 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
2139 then
2140         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
2141 fi
2142 AC_SUBST(USE_ARG_SUFFIX)
2143 AC_SUBST(USE_CFG_SUFFIX)
2144 AC_SUBST(USE_LIB_SUFFIX)
2145
2146 if test "$with_ticlib" != no ; then
2147
2148         if test "x$with_ticlib" != xyes ; then
2149                 TICS_NAME=$with_ticlib
2150                 TICS_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2151                 TICS_ARG_SUFFIX="${with_ticlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2152                 TICS_DEP_SUFFIX="${with_ticlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2153                 TICS_LIB_SUFFIX="${with_ticlib}"
2154         else
2155                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
2156                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
2157                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
2158                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
2159         fi
2160         TICS_LDFLAGS="-L${LIB_DIR}"
2161         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
2162 else
2163         TICS_SUFFIX=${DFT_LIB_SUFFIX}
2164         TICS_LDFLAGS="-L${LIB_DIR}"
2165         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2166 fi
2167 AC_SUBST(TICS_ARG_SUFFIX)
2168 AC_SUBST(TICS_DEP_SUFFIX)
2169 AC_SUBST(TICS_LIB_SUFFIX)
2170 AC_SUBST(TICS_LDFLAGS)
2171 AC_SUBST(TICS_LIBS)
2172
2173 if test "$with_termlib" != no ; then
2174
2175         if test "x$with_termlib" != xyes ; then
2176                 TINFO_NAME=$with_termlib
2177                 TINFO_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2178                 TINFO_ARG_SUFFIX="${with_termlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2179                 TINFO_DEP_SUFFIX="${with_termlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2180                 TINFO_LIB_SUFFIX="${with_termlib}"
2181         else
2182                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2183                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2184                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2185                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2186         fi
2187
2188         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2189         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2190         if test "$DFT_LWR_MODEL" = "libtool"; then
2191                 TEST_ARGS="${TEST_DEPS}"
2192                 TEST_ARG2="${TEST_DEP2}"
2193                 TINFO_LDFLAGS="-L${LIB_DIR}"
2194                 TINFO_LIBS="$TEST_ARGS"
2195                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2196                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2197         else
2198                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2199                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2200                 if test "x$with_term_driver" != xno ; then
2201                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2202                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2203                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2204                 else
2205                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2206                         TINFO_LIBS="$TEST_ARGS"
2207                 fi
2208                 TINFO_LDFLAGS="-L${LIB_DIR}"
2209                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2210         fi
2211 else
2212         # the next lines are needed for linking libtic over libncurses
2213         TINFO_NAME=${LIB_NAME}
2214         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2215         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2216         if test "x$with_tic_depends" = xyes ; then
2217                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2218         else
2219                 TICS_LIST="$SHLIB_LIST"
2220         fi
2221
2222         TINFO_LDFLAGS="-L${LIB_DIR}"
2223         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2224 fi
2225
2226 if test "$DFT_LWR_MODEL" = shared ; then
2227         case "$cf_cv_system_name" in
2228         (cygwin*|msys*)
2229                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2230                 TINFO_SUFFIX=.dll
2231                 ;;
2232         esac
2233 fi
2234
2235 AC_SUBST(TINFO_ARG_SUFFIX)
2236 AC_SUBST(TINFO_DEP_SUFFIX)
2237 AC_SUBST(TINFO_LIB_SUFFIX)
2238 AC_SUBST(TINFO_LDFLAGS)
2239 AC_SUBST(TINFO_LIBS)
2240
2241 if test "x$with_dlsym" = xyes ; then
2242         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2243 fi
2244
2245 if test "$DFT_LWR_MODEL" = "libtool"; then
2246         OBJEXT=lo
2247 fi
2248
2249 # needed for Ada95
2250 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2251 AC_SUBST(TINFO_LDFLAGS2)
2252
2253 case "$DFT_LWR_MODEL" in
2254 (normal|debug|profile)
2255         CF_LDFLAGS_STATIC
2256         ;;
2257 esac
2258
2259 AC_MSG_CHECKING(where we will install curses.h)
2260 AC_SUBST(includesubdir)
2261 includesubdir=
2262 if test "$with_overwrite" = no && \
2263  { test "x$includedir" = 'x${prefix}/include' || \
2264    test "x$includedir" = "x${prefix}/include"; }
2265 then
2266         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2267 fi
2268 AC_MSG_RESULT(${includedir}${includesubdir})
2269
2270 ### Resolve a conflict between normal and wide-curses by forcing applications
2271 ### that will need libutf8 to add it to their configure script.
2272 if test "$with_overwrite" != no ; then
2273 if test "$NCURSES_LIBUTF8" = 1 ; then
2274         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2275         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2276 fi
2277 fi
2278 WITH_OVERWRITE=$with_overwrite
2279
2280 ### At least on MinGW a shared library build without libtool
2281 ### requires adding the additional libs to the link list.
2282 case "$cf_cv_system_name" in
2283 (*mingw32*|*mingw64*)
2284         if test "$DFT_LWR_MODEL" != "libtool"; then
2285            SHLIB_LIST="$SHLIB_LIST ${LIBS}"
2286         fi
2287         ;;
2288 *)      ;;
2289 esac
2290
2291 AC_SUBST(WITH_OVERWRITE)
2292 AC_SUBST(TICS_LIST)
2293 AC_SUBST(TINFO_LIST)
2294 AC_SUBST(SHLIB_LIST)
2295
2296 # used to separate tack out of the tree
2297 NCURSES_TREE=
2298 AC_SUBST(NCURSES_TREE)
2299
2300 ### predefined stuff for the test programs
2301 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2302
2303 # pkgsrc uses these
2304 CF_WITH_LIB_BASENAME(FORM_NAME,form)
2305 CF_WITH_LIB_BASENAME(MENU_NAME,menu)
2306 CF_WITH_LIB_BASENAME(PANEL_NAME,panel)
2307 CF_WITH_LIB_BASENAME(CXX_NAME,cxx,ncurses++)
2308
2309 ### Construct the list of subdirectories for which we'll customize makefiles
2310 ### with the appropriate compile-rules.
2311
2312 CF_SRC_MODULES($modules_to_build)
2313
2314 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2315    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/src/library.gpr:Ada95/src/library.gpr.in"
2316    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2317    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2318 fi
2319
2320 CF_DIRS_TO_MAKE
2321
2322 # symbols that differ when compiling Ada95 by itself.
2323 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2324 AC_SUBST(NCURSES_SHLIB2)
2325
2326 # values to use as strings
2327 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2328
2329 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2330
2331 ### Define substitutions for header files to avoid name-pollution
2332 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2333 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2334 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2335 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2336
2337 ################################################################################
2338 test "x$use_database" = xyes && \
2339 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2340
2341 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2342 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2343
2344 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2345 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2346 fi
2347 AC_SUBST(cross_compiling)
2348
2349 if test "x$cf_with_tests" != xno ; then
2350         MAKE_TESTS=
2351 else
2352         MAKE_TESTS="#"
2353 fi
2354 AC_SUBST(MAKE_TESTS)
2355
2356 ADAHTML_DIR=../../doc/html/ada
2357 AC_SUBST(ADAHTML_DIR)
2358
2359 # workaround for OS/2 (20151017)
2360 case "$cf_cv_system_name" in
2361 (os2*)
2362         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2363         ;;
2364 (*)
2365         LIBTOOL_OPTS_CXX=
2366         ;;
2367 esac
2368 AC_SUBST(LIBTOOL_OPTS_CXX)
2369
2370 # workaround for g++ versus Solaris (20131116)
2371 case "$cf_cv_system_name" in
2372 (solaris2*)
2373         case "x$CPPFLAGS" in
2374         (*-D_XOPEN_SOURCE_EXTENDED*)
2375                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2376                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2377                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2378                 ;;
2379         esac
2380         ;;
2381 esac
2382
2383 # Help to automatically enable the extended curses features when using either
2384 # the *-config or the ".pc" files by adding defines.
2385 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2386 PKG_CFLAGS=
2387 for cf_loop1 in $CPPFLAGS_after_XOPEN
2388 do
2389         cf_found=no
2390         for cf_loop2 in $CPPFLAGS_before_XOPEN
2391         do
2392                 if test "x$cf_loop1" = "x$cf_loop2"
2393                 then
2394                         cf_found=yes
2395                         break
2396                 fi
2397         done
2398         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2399 done
2400 AC_MSG_RESULT($PKG_CFLAGS)
2401 AC_SUBST(PKG_CFLAGS)
2402
2403 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2404 case "x$NCURSES_OSPEED" in
2405 (*short*)
2406         cf_compatible=1
2407         ;;
2408 (*)
2409         cf_compatible=0
2410         ;;
2411 esac
2412 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2413
2414 case "x$cf_cv_typeof_chtype" in
2415 (xshort|xint|xlong)
2416         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2417         ;;
2418 esac
2419
2420 case "x$cf_cv_typeof_mmask_t" in
2421 (xshort|xint|xlong)
2422         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2423         ;;
2424 esac
2425
2426 # substitute into misc/Makefile to suppress
2427 # (un)install.data from the
2428 # (un)install rules.
2429 if test "x$cf_with_db_install" = "xno"; then
2430         MISC_INSTALL_DATA=
2431         MISC_UNINSTALL_DATA=
2432 else
2433         MISC_INSTALL_DATA=install.data
2434         MISC_UNINSTALL_DATA=uninstall.data
2435 fi
2436 AC_SUBST(MISC_INSTALL_DATA)
2437 AC_SUBST(MISC_UNINSTALL_DATA)
2438
2439 if test "x$cf_with_db_install" = "xno" || test "x$TERMINFO_SRC" = "xno"; then
2440         MAKE_DATABASE="#"
2441 else
2442         MAKE_DATABASE="$MAKE_TERMINFO"
2443 fi
2444 AC_SUBST(MAKE_DATABASE)
2445
2446 dnl Override the package used for exported symbols
2447 if test -n "$PACKAGE"
2448 then
2449         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2450         export PACKAGE
2451         echo "package: $PACKAGE"
2452 fi
2453
2454 UNALTERED_SYMS=
2455 cf_filter_syms=no
2456
2457 if test -n "$RESULTING_SYMS"
2458 then
2459         cf_filter_syms=$cf_dft_filter_syms
2460         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_version)
2461 fi
2462
2463 if test "x$WILDCARD_SYMS" = xno
2464 then
2465         cf_filter_syms=yes
2466 fi
2467
2468 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2469
2470 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2471 if test "$cf_filter_syms" = yes
2472 then
2473         RESULTING_SYMS=resulting.map
2474 fi
2475 AC_SUBST(UNALTERED_SYMS)
2476
2477 if test "x$cross_compiling" = xyes ; then
2478         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2479         CHECK_BUILD="#"
2480 else
2481         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2482         CHECK_BUILD=
2483 fi
2484 AC_SUBST(ADAGEN_LDFLAGS)
2485 AC_SUBST(CHECK_BUILD)
2486 AC_SUBST(PRIVATE_LIBS)
2487
2488 # This is used for the *-config script and *.pc data files.
2489 CF_LD_SEARCHPATH
2490
2491 AC_DEFINE(HAVE_CURSES_DATA_BOOLNAMES,1,[definition needed for in-tree build of tack])
2492
2493 AC_OUTPUT( \
2494         include/MKterm.h.awk \
2495         include/curses.head:include/curses.h.in \
2496         include/ncurses_dll.h \
2497         include/termcap.h \
2498         include/unctrl.h \
2499         $SUB_MAKEFILES \
2500         Makefile,[
2501 if test "x$cf_with_tests" != xno ; then
2502         CF_PRG_RULES(["$srcdir/test/mk-test.awk" INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2503 fi
2504 CF_LIB_RULES($SRC_SUBDIRS)
2505
2506 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2507 if test -z "$USE_OLD_MAKERULES" ; then
2508         $AWK -f "$srcdir/Ada95/mk-1st.awk" <"$srcdir/Ada95/src/modules" >>Ada95/src/Makefile
2509 fi
2510 fi
2511 ],[
2512 ### Special initialization commands, used to pass information from the
2513 ### configuration-run into config.status
2514
2515 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2516 AWK="$AWK"
2517 CXX_NAME="$CXX_NAME"
2518 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2519 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2520 ECHO_LD="$ECHO_LD"
2521 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2522 FORM_NAME="$FORM_NAME"
2523 LDCONFIG="$LDCONFIG"
2524 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2525 LIB_NAME="$LIB_NAME"
2526 LIB_PREFIX="$LIB_PREFIX"
2527 LIB_SUBSETS="$LIB_SUBSETS"
2528 LIB_SUFFIX="$LIB_SUFFIX"
2529 LIB_TRACING="$LIB_TRACING"
2530 LN_S="$LN_S"
2531 MAKE_TERMINFO="$MAKE_TERMINFO"
2532 MENU_NAME="$MENU_NAME"
2533 NCURSES_MAJOR="$NCURSES_MAJOR"
2534 NCURSES_MINOR="$NCURSES_MINOR"
2535 NCURSES_OSPEED="$NCURSES_OSPEED"
2536 NCURSES_PATCH="$NCURSES_PATCH"
2537 PANEL_NAME="$PANEL_NAME"
2538 SRC_SUBDIRS="$SRC_SUBDIRS"
2539 TERMINFO="$TERMINFO"
2540 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2541 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2542 TICS_NAME="$TICS_NAME"
2543 TICS_SUFFIX="$TICS_SUFFIX"
2544 TIC_PATH="$TIC_PATH"
2545 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2546 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2547 TINFO_NAME="$TINFO_NAME"
2548 TINFO_SUFFIX="$TINFO_SUFFIX"
2549 UNALTERED_SYMS="$UNALTERED_SYMS"
2550 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2551 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2552 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2553 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2554 WILDCARD_SYMS="$WILDCARD_SYMS"
2555 WITH_CURSES_H="$with_curses_h"
2556 WITH_ECHO="${enable_echo:=yes}"
2557 WITH_OVERWRITE="$with_overwrite"
2558 cf_LIST_MODELS="$cf_list_models"
2559 cf_cv_VERSION_GNATMAKE=$cf_cv_VERSION_GNATMAKE
2560 cf_cv_VERSION_GPRBUILD=$cf_cv_VERSION_GPRBUILD
2561 cf_cv_abi_version="$cf_cv_abi_version"
2562 cf_cv_do_relink="$cf_cv_do_relink"
2563 cf_cv_do_reranlib="$cf_cv_do_reranlib"
2564 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2565 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2566 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2567 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2568 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2569 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2570 cf_cv_rel_version="$cf_cv_rel_version"
2571 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2572 cf_cv_shared_soname='$cf_cv_shared_soname'
2573 cf_cv_shlib_version="$cf_cv_shlib_version"
2574 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2575 cf_cv_system_name="$cf_cv_system_name"
2576 cf_cv_term_driver="$with_term_driver"
2577 cf_with_ada="$cf_with_ada"
2578 cf_with_cxx_binding="$cf_with_cxx_binding"
2579 cf_with_db_install="$cf_with_db_install"
2580 cf_with_manpages="$cf_with_manpages"
2581 cf_with_tests="$cf_with_tests"
2582 host="$host"
2583 target="$target"
2584 with_shared_cxx="$with_shared_cxx"
2585
2586 ],cat)dnl
2587 ${MAKE:-make} preinstall