configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2006,2007 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.406 2007/03/10 18:06:55 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.13.20020210)
  38 AC_REVISION($Revision: 1.406 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44
  45 CF_WITH_REL_VERSION(NCURSES)
  46 CF_WITH_ABI_VERSION
  47
  48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
  49 AC_ARG_WITH(system-type,
  50 [  --with-system-type=XXX  test: override derived host system-type],
  51 [AC_MSG_WARN(overriding system type to $withval)
  52  cf_cv_system_name=$withval])
  53
  54 ###     Save the given $CFLAGS to allow user-override.
  55 cf_user_CFLAGS="$CFLAGS"
  56
  57 ###     Default install-location
  58 CF_CFG_DEFAULTS
  59
  60 ###     Checks for programs.
  61 AC_PROG_CC
  62 CF_GCC_VERSION
  63
  64 AC_PROG_CPP
  65 AC_PROG_GCC_TRADITIONAL
  66 CF_PROG_CC_C_O(CC)
  67 AC_ISC_POSIX
  68 CF_ANSI_CC_REQD
  69 CF_PROG_EXT
  70 CF_PROG_LDCONFIG
  71
  72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  73 dnl                             configure script by not letting us test if C++
  74 dnl                             is present, making this option necessary.
  75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  76 AC_ARG_WITH(cxx,
  77         [  --without-cxx           do not adjust ncurses bool to match C++],
  78         [cf_with_cxx=$withval],
  79         [cf_with_cxx=yes])
  80 AC_MSG_RESULT($cf_with_cxx)
  81 if test "X$cf_with_cxx" = Xno ; then
  82         CXX=""
  83         GXX=""
  84 else
  85         # with autoconf 2.13, we can change the error to a warning:
  86         pushdef([AC_MSG_ERROR],
  87                 [AC_MSG_RESULT(no)
  88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  90         AC_PROG_CXX
  91         popdef([AC_MSG_ERROR])dnl
  92         # autoconf 2.5x removed the error - by hardcoding it to g++.
  93         if test "$CXX" = "g++" ; then
  94                 AC_PATH_PROG(CXX,g++)
  95         fi
  96         if test "$CXX" = "g++" ; then
  97                 AC_MSG_WARN(ignoring hardcoded g++)
  98                 cf_with_cxx=no; CXX=""; GXX="";
  99         fi
 100 fi
 101
 102 CF_GXX_VERSION
 103 case $GXX_VERSION in
 104 1*|2.[[0-6]]*)
 105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 106         # cf_cxx_library=no
 107         AC_MSG_WARN(templates do not work)
 108         ;;
 109 esac
 110
 111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 112 AC_ARG_WITH(cxx-binding,
 113         [  --without-cxx-binding   do not build C++ binding and demo],
 114         [cf_with_cxx_binding=$withval],
 115         [cf_with_cxx_binding=$cf_with_cxx])
 116 AC_MSG_RESULT($cf_with_cxx_binding)
 117
 118 AC_MSG_CHECKING(if you want to build with Ada95)
 119 AC_ARG_WITH(ada,
 120         [  --without-ada           suppress check for Ada95, don't build demo],
 121         [cf_with_ada=$withval],
 122         [cf_with_ada=yes])
 123 AC_MSG_RESULT($cf_with_ada)
 124
 125 AC_MSG_CHECKING(if you want to build programs such as tic)
 126 AC_ARG_WITH(progs,
 127         [  --without-progs         suppress build with programs (e.g., tic)],
 128         [cf_with_progs=$withval],
 129         [cf_with_progs=yes])
 130 AC_MSG_RESULT($cf_with_progs)
 131
 132 AC_MSG_CHECKING(if you wish to install curses.h)
 133 AC_ARG_WITH(curses-h,
 134         [  --without-curses-h      install curses.h as ncurses.h only],
 135         [with_curses_h=$withval],
 136         [with_curses_h=yes])
 137 AC_MSG_RESULT($with_curses_h)
 138
 139 modules_to_build="ncurses"
 140 if test "X$cf_with_progs" != Xno ; then
 141 modules_to_build="$modules_to_build progs tack"
 142 fi
 143 modules_to_build="$modules_to_build panel menu form"
 144
 145 AC_ARG_PROGRAM
 146
 147 CF_PROG_AWK
 148 CF_PROG_EGREP
 149 CF_PROG_INSTALL
 150 CF_PROG_LINT
 151 AC_PROG_LN_S
 152
 153 AC_PROG_MAKE_SET
 154 CF_MAKE_TAGS
 155 CF_MAKEFLAGS
 156
 157 AC_SYS_LONG_FILE_NAMES
 158 CF_MIXEDCASE_FILENAMES
 159
 160 dnl These are standard among *NIX systems, but not when cross-compiling
 161 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 162 AC_CHECK_TOOL(LD, ld, ld)
 163 AC_CHECK_TOOL(AR, ar, ar)
 164 CF_SUBST(archiver options,AR_OPTS,rv)
 165
 166 dnl Special option for use by system-builders: the install-prefix is used to
 167 dnl adjust the location into which the actual install is done, so that an
 168 dnl archive can be built without modifying the host system's configuration.
 169 AC_MSG_CHECKING(if you have specified an install-prefix)
 170 AC_ARG_WITH(install-prefix,
 171         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 172         [case "$withval" in #(vi
 173         yes|no) #(vi
 174                 ;;
 175         *)      DESTDIR="$withval"
 176                 ;;
 177         esac])
 178 AC_MSG_RESULT($DESTDIR)
 179 AC_SUBST(DESTDIR)
 180
 181 ###############################################################################
 182 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 183 # If we're cross-compiling, allow the user to override the tools and their
 184 # options.  The configure script is oriented toward identifying the host
 185 # compiler, etc., but we need a build compiler to generate parts of the source.
 186 CF_BUILD_CC
 187
 188 ###############################################################################
 189 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 190
 191 ### Options to allow the user to specify the set of libraries which are used.
 192 ### Use "--without-normal --with-shared" to allow the default model to be
 193 ### shared, for example.
 194 cf_list_models=""
 195 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 196
 197 CF_WITH_LIBTOOL
 198 if test "$with_libtool" != "no" ; then
 199
 200 cf_list_models="$cf_list_models libtool"
 201
 202 else
 203
 204 AC_MSG_CHECKING(if you want to build shared libraries)
 205 AC_ARG_WITH(shared,
 206         [  --with-shared           generate shared-libraries],
 207         [with_shared=$withval],
 208         [with_shared=no])
 209 AC_MSG_RESULT($with_shared)
 210 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
 211
 212 AC_MSG_CHECKING(if you want to build static libraries)
 213 AC_ARG_WITH(normal,
 214         [  --with-normal           generate normal-libraries (default)],
 215         [with_normal=$withval],
 216         [with_normal=yes])
 217 AC_MSG_RESULT($with_normal)
 218 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
 219
 220 AC_MSG_CHECKING(if you want to build debug libraries)
 221 AC_ARG_WITH(debug,
 222         [  --with-debug            generate debug-libraries (default)],
 223         [with_debug=$withval],
 224         [with_debug=yes])
 225 AC_MSG_RESULT($with_debug)
 226 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
 227
 228 AC_MSG_CHECKING(if you want to build profiling libraries)
 229 AC_ARG_WITH(profile,
 230         [  --with-profile          generate profile-libraries],
 231         [with_profile=$withval],
 232         [with_profile=no])
 233 AC_MSG_RESULT($with_profile)
 234 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
 235
 236 fi
 237
 238 ###############################################################################
 239
 240 AC_MSG_CHECKING(for specified models)
 241 test -z "$cf_list_models" && cf_list_models=normal
 242 dnl If we use libtool to generate libraries, then it must be the only
 243 dnl specified model.
 244 test "$with_libtool" != "no" && cf_list_models=libtool
 245 AC_MSG_RESULT($cf_list_models)
 246
 247 ### Use the first model as the default, and save its suffix for use in building
 248 ### up test-applications.
 249 AC_MSG_CHECKING(for default model)
 250 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 251 AC_MSG_RESULT($DFT_LWR_MODEL)
 252
 253 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 254
 255 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 256 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 257
 258 TICS_NAME=tic
 259 AC_SUBST(TICS_NAME)
 260
 261 TINFO_NAME=tinfo
 262 AC_SUBST(TINFO_NAME)
 263
 264 LIB_NAME=ncurses
 265 AC_SUBST(LIB_NAME)
 266
 267 LIB_DIR=../lib
 268 LIB_2ND=../../lib
 269
 270 CF_LIB_PREFIX(cf_prefix)
 271 LIB_PREFIX=$cf_prefix
 272 AC_SUBST(LIB_PREFIX)
 273
 274 LIB_SUFFIX=
 275 AC_SUBST(LIB_SUFFIX)
 276
 277 ###############################################################################
 278
 279 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 280 AC_ARG_WITH(termlib,
 281         [  --with-termlib          generate separate terminfo library],
 282         [with_termlib=$withval],
 283         [with_termlib=no])
 284 AC_MSG_RESULT($with_termlib)
 285
 286 AC_MSG_CHECKING(if you want to build a separate tic library)
 287 AC_ARG_WITH(ticlib,
 288         [  --with-ticlib           generate separate tic library],
 289         [with_ticlib=$withval],
 290         [with_ticlib=no])
 291 AC_MSG_RESULT($with_ticlib)
 292
 293 ### Checks for special libraries, must be done up-front.
 294 SHLIB_LIST=""
 295 CF_WITH_GPM
 296 if test "$with_gpm" != no ; then
 297         AC_MSG_CHECKING(if you want to load GPM dynamically)
 298         AC_ARG_WITH(dlsym,
 299                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 300                 [with_dlsym=$withval],
 301                 [with_dlsym=yes])
 302         AC_MSG_RESULT($with_dlsym)
 303         if test "$with_dlsym" = yes ; then
 304                 CF_FUNC_DLSYM
 305                 if test "$with_gpm" != yes ; then
 306                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 307                         cf_cv_gpm_soname="$with_gpm"
 308                 else
 309                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 310                 fi
 311                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
 312                 SHLIB_LIST="-ldl $SHLIB_LIST"
 313         else
 314                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 315         fi
 316         AC_DEFINE(HAVE_LIBGPM)
 317         AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 318                 AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 319         ])
 320 fi
 321
 322 CF_WITH_SYSMOUSE
 323
 324 dnl Not all ports of gcc support the -g option
 325
 326 if test X"$CC_G_OPT" = X"" ; then
 327         CC_G_OPT='-g'
 328         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
 329 fi
 330 AC_SUBST(CC_G_OPT)
 331
 332 if test X"$CXX_G_OPT" = X"" ; then
 333         CXX_G_OPT='-g'
 334         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
 335 fi
 336 AC_SUBST(CXX_G_OPT)
 337
 338 AC_MSG_CHECKING(for default loader flags)
 339 case $DFT_LWR_MODEL in
 340 libtool) LD_MODEL=''   ;;
 341 normal)  LD_MODEL=''   ;;
 342 debug)   LD_MODEL=$CC_G_OPT ;;
 343 profile) LD_MODEL='-pg';;
 344 shared)  LD_MODEL=''   ;;
 345 esac
 346 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 347 AC_MSG_RESULT($LD_MODEL)
 348
 349 case $DFT_LWR_MODEL in
 350 shared)
 351 AC_MSG_CHECKING(if rpath option should be used)
 352 AC_ARG_ENABLE(rpath,
 353 [  --enable-rpath          use rpath option when generating shared libraries],
 354 [cf_cv_ld_rpath=$enableval],
 355 [cf_cv_ld_rpath=no])
 356 AC_MSG_RESULT($cf_cv_ld_rpath)
 357 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 358 AC_ARG_ENABLE(rpath,
 359 [  --disable-relink        relink shared libraries during install],
 360 [cf_cv_do_relink=$enableval],
 361 [cf_cv_do_relink=yes])
 362 AC_MSG_RESULT($cf_cv_do_relink)
 363         ;;
 364 esac
 365
 366 CF_SHARED_OPTS
 367 if test "$CC_SHARED_OPTS" = "unknown"; then
 368         for model in $cf_list_models; do
 369                 if test "$model" = "shared"; then
 370                         AC_ERROR(Shared libraries are not supported in this version)
 371                 fi
 372         done
 373 fi
 374
 375 ###############################################################################
 376 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 377
 378 ###     use option --disable-overwrite to leave out the link to -lcurses
 379 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 380 AC_ARG_ENABLE(overwrite,
 381         [  --disable-overwrite     leave out the link to -lcurses],
 382         [with_overwrite=$enableval],
 383         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 384 AC_MSG_RESULT($with_overwrite)
 385
 386 AC_MSG_CHECKING(if external terminfo-database is used)
 387 AC_ARG_ENABLE(database,
 388         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 389         [use_database=$enableval],
 390         [use_database=yes])
 391 AC_MSG_RESULT($use_database)
 392
 393 case $host_os in #(vi
 394 os2*) #(vi
 395         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 396         ;;
 397 *) #(vi
 398         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 399         ;;
 400 esac
 401 AC_SUBST(TERMINFO_SRC)
 402
 403 CF_PATHSEP
 404 if test "$use_database" != no ; then
 405         AC_DEFINE(USE_DATABASE)
 406
 407         AC_MSG_CHECKING(which terminfo source-file will be installed)
 408         AC_ARG_ENABLE(database,
 409                 [  --with-database=XXX     specify terminfo source to install],
 410                 [TERMINFO_SRC=$withval])
 411         AC_MSG_RESULT($TERMINFO_SRC)
 412
 413         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 414         AC_ARG_WITH(hashed-db,
 415                 [  --with-hashed-db        specify hashed-database library],,
 416                 [with_hashed_db=no])
 417         AC_MSG_RESULT($with_hashed_db)
 418 fi
 419
 420 AC_MSG_CHECKING(for list of fallback descriptions)
 421 AC_ARG_WITH(fallbacks,
 422         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 423         [with_fallback=$withval],
 424         [with_fallback=])
 425 AC_MSG_RESULT($with_fallback)
 426 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 427 AC_SUBST(FALLBACK_LIST)
 428
 429 AC_MSG_CHECKING(if you want modern xterm or antique)
 430 AC_ARG_WITH(xterm-new,
 431         [  --without-xterm-new     specify if xterm terminfo should be old version],
 432         [with_xterm_new=$withval],
 433         [with_xterm_new=yes])
 434 case $with_xterm_new in
 435 no)     with_xterm_new=xterm-old;;
 436 *)      with_xterm_new=xterm-new;;
 437 esac
 438 AC_MSG_RESULT($with_xterm_new)
 439 WHICH_XTERM=$with_xterm_new
 440 AC_SUBST(WHICH_XTERM)
 441
 442 MAKE_TERMINFO=
 443 if test "$use_database" = no ; then
 444         TERMINFO="${datadir}/terminfo"
 445         MAKE_TERMINFO="#"
 446 else
 447
 448 AC_MSG_CHECKING(for list of terminfo directories)
 449 CF_WITH_PATHLIST(terminfo-dirs,
 450         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 451         TERMINFO_DIRS,
 452         DATADIR/terminfo,
 453         ${datadir}/terminfo)
 454 AC_MSG_RESULT($TERMINFO_DIRS)
 455 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
 456
 457 AC_MSG_CHECKING(for default terminfo directory)
 458 CF_WITH_PATH(default-terminfo-dir,
 459         [  --with-default-terminfo-dir=DIR default terminfo directory],
 460         TERMINFO,
 461         DATADIR/terminfo,
 462         ${datadir}/terminfo)
 463 AC_MSG_RESULT($TERMINFO)
 464 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
 465
 466 fi
 467
 468 AC_SUBST(TERMINFO)
 469 AC_SUBST(MAKE_TERMINFO)
 470
 471 ###     use option --disable-big-core to make tic run on small machines
 472 ###     We need 4Mb, check if we can allocate 50% more than that.
 473 AC_MSG_CHECKING(if big-core option selected)
 474 AC_ARG_ENABLE(big-core,
 475         [  --disable-big-core      assume machine has little memory],
 476         [with_big_core=$enableval],
 477         [AC_TRY_RUN([
 478 #include <stdlib.h>
 479 #include <string.h>
 480 int main() {
 481         unsigned long n = 6000000L;
 482         char *s = malloc(n);
 483         if (s != 0)
 484                 s[0] = s[n-1] = 0;
 485         ${cf_cv_main_return:-return}(s == 0);
 486 }],
 487         [with_big_core=yes],
 488         [with_big_core=no],
 489         [with_big_core=no])])
 490 AC_MSG_RESULT($with_big_core)
 491 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
 492
 493 ###     use option --enable-termcap to compile in the termcap fallback support
 494 AC_MSG_CHECKING(if you want termcap-fallback support)
 495 AC_ARG_ENABLE(termcap,
 496         [  --enable-termcap        compile in termcap fallback support],
 497         [with_termcap=$enableval],
 498         [with_termcap=no])
 499 AC_MSG_RESULT($with_termcap)
 500
 501 if test "$with_termcap" != "yes" ; then
 502         if test "$use_database" = no ; then
 503                 if test -z "$with_fallback" ; then
 504                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 505                 fi
 506         fi
 507         AC_DEFINE(PURE_TERMINFO)
 508 else
 509
 510 if test "$with_ticlib" != no ; then
 511         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 512 fi
 513
 514 AC_DEFINE(USE_TERMCAP)
 515 AC_MSG_CHECKING(for list of termcap files)
 516 CF_WITH_PATHLIST(termpath,
 517         [  --with-termpath=XXX     specify list of termcap files],
 518         TERMPATH,
 519         /etc/termcap:/usr/share/misc/termcap)
 520 AC_MSG_RESULT($TERMPATH)
 521 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
 522
 523 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 524 AC_MSG_CHECKING(if fast termcap-loader is needed)
 525 AC_ARG_ENABLE(getcap,
 526         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 527         [with_getcap=$enableval],
 528         [with_getcap=no])
 529 AC_MSG_RESULT($with_getcap)
 530 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
 531
 532 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 533 AC_ARG_ENABLE(getcap-cache,
 534         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 535         [with_getcap_cache=$enableval],
 536         [with_getcap_cache=no])
 537 AC_MSG_RESULT($with_getcap_cache)
 538 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
 539
 540 fi
 541
 542 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 543 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 544 AC_ARG_ENABLE(home-terminfo,
 545         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 546         [with_home_terminfo=$enableval],
 547         [with_home_terminfo=yes])
 548 AC_MSG_RESULT($with_home_terminfo)
 549 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
 550
 551 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 552 AC_ARG_ENABLE(root-environ,
 553         [  --disable-root-environ  restrict environment when running as root],
 554         [with_root_environ=$enableval],
 555         [with_root_environ=yes])
 556 AC_MSG_RESULT($with_root_environ)
 557 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
 558
 559 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 560 ###   to reduce storage requirements for the terminfo database.
 561 CF_LINK_FUNCS
 562
 563 with_links=no
 564 with_symlinks=no
 565
 566 # soft links (symbolic links) are useful for some systems where hard links do
 567 # not work, or to make it simpler to copy terminfo trees around.
 568 if test "$ac_cv_func_symlink" = yes ; then
 569     AC_MSG_CHECKING(if tic should use symbolic links)
 570     AC_ARG_ENABLE(symlinks,
 571         [  --enable-symlinks       make tic use symbolic links not hard links],
 572         [with_symlinks=$enableval],
 573         [with_symlinks=no])
 574     AC_MSG_RESULT($with_symlinks)
 575 fi
 576
 577 # If we have hard links and did not choose to use soft links instead, there is
 578 # no reason to make this choice optional - use the hard links.
 579 if test "$with_symlinks" = no ; then
 580     AC_MSG_CHECKING(if tic should use hard links)
 581     if test "$ac_cv_func_link" = yes ; then
 582         with_links=yes
 583     else
 584         with_links=no
 585     fi
 586     AC_MSG_RESULT($with_links)
 587 fi
 588
 589 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
 590 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
 591
 592 ###   use option --enable-broken-linker to force on use of broken-linker support
 593 AC_MSG_CHECKING(if you want broken-linker support code)
 594 AC_ARG_ENABLE(broken_linker,
 595         [  --enable-broken_linker  compile with broken-linker support code],
 596         [with_broken_linker=$enableval],
 597         [with_broken_linker=${BROKEN_LINKER-no}])
 598 AC_MSG_RESULT($with_broken_linker)
 599
 600 BROKEN_LINKER=0
 601 if test "$with_broken_linker" = yes ; then
 602         AC_DEFINE(BROKEN_LINKER)
 603         BROKEN_LINKER=1
 604 elif test "$DFT_LWR_MODEL" = shared ; then
 605         case $cf_cv_system_name in #(vi
 606         cygwin*)
 607                 AC_DEFINE(BROKEN_LINKER)
 608                 BROKEN_LINKER=1
 609                 CF_VERBOSE(cygwin linker is broken anyway)
 610                 ;;
 611         esac
 612 fi
 613 AC_SUBST(BROKEN_LINKER)
 614
 615 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 616 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 617 AC_ARG_ENABLE(bsdpad,
 618         [  --enable-bsdpad         recognize BSD-style prefix padding],
 619         [with_bsdpad=$enableval],
 620         [with_bsdpad=no])
 621 AC_MSG_RESULT($with_bsdpad)
 622 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
 623
 624 ###   use option --enable-widec to turn on use of wide-character support
 625 NCURSES_CH_T=chtype
 626 NCURSES_LIBUTF8=0
 627
 628 NEED_WCHAR_H=0
 629 NCURSES_MBSTATE_T=0
 630 NCURSES_WCHAR_T=0
 631 NCURSES_WINT_T=0
 632
 633 # Check to define _XOPEN_SOURCE "automatically"
 634 CF_XOPEN_SOURCE
 635
 636 # Work around breakage on OS X
 637 CF_SIGWINCH
 638
 639 # Checks for CODESET support.
 640 AM_LANGINFO_CODESET
 641
 642 # use these variables to work around a defect in gcc's fixincludes.
 643 NCURSES_OK_WCHAR_T=
 644 NCURSES_OK_WINT_T=
 645
 646 AC_MSG_CHECKING(if you want wide-character code)
 647 AC_ARG_ENABLE(widec,
 648         [  --enable-widec          compile with wide-char/UTF-8 code],
 649         [with_widec=$enableval],
 650         [with_widec=no])
 651 AC_MSG_RESULT($with_widec)
 652 if test "$with_widec" = yes ; then
 653         LIB_SUFFIX="w${LIB_SUFFIX}"
 654         AC_DEFINE(USE_WIDEC_SUPPORT)
 655         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 656         # with_overwrite=no
 657         NCURSES_CH_T=cchar_t
 658         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc)
 659         if test "$ac_cv_func_putwc" != yes ; then
 660                 CF_LIBUTF8
 661                 if test "$cf_cv_libutf8" = yes ; then
 662                         NCURSES_LIBUTF8=1
 663                 fi
 664         fi
 665         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 666         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 667         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 668
 669         if test "$NCURSES_MBSTATE_T" != 0; then
 670                 AC_DEFINE(NEED_MBSTATE_T_DEF)
 671         fi
 672 fi
 673 AC_SUBST(NCURSES_CH_T)
 674 AC_SUBST(NCURSES_LIBUTF8)
 675
 676 AC_SUBST(NEED_WCHAR_H)
 677 AC_SUBST(NCURSES_MBSTATE_T)
 678 AC_SUBST(NCURSES_WCHAR_T)
 679 AC_SUBST(NCURSES_WINT_T)
 680
 681 AC_SUBST(NCURSES_OK_WCHAR_T)
 682 AC_SUBST(NCURSES_OK_WINT_T)
 683
 684 ###   use option --disable-lp64 to allow long chtype
 685 case $cf_cv_abi_version in
 686 [[345]]*)
 687         default_with_lp64=no
 688         ;;
 689 *)
 690         default_with_lp64=yes
 691         ;;
 692 esac
 693
 694 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 695 AC_ARG_ENABLE(lp64,
 696         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 697         [with_lp64=$enableval],
 698         [with_lp64=$default_with_lp64])
 699 AC_MSG_RESULT($with_lp64)
 700
 701 if test "$with_lp64" = yes ; then
 702         cf_cv_enable_lp64=1
 703 else
 704         cf_cv_enable_lp64=0
 705 fi
 706 AC_SUBST(cf_cv_enable_lp64)
 707
 708 CF_LARGEFILE
 709
 710 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 711 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 712 AC_ARG_ENABLE(tparm-varargs,
 713         [  --disable-tparm-varargs compile tparm() without varargs interface],
 714         [with_tparm_varargs=$enableval],
 715         [with_tparm_varargs=yes])
 716 AC_MSG_RESULT($with_tparm_varargs)
 717 NCURSES_TPARM_VARARGS=0
 718 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
 719 AC_SUBST(NCURSES_TPARM_VARARGS)
 720
 721 ###   use option --with-bool to override bool's type
 722 AC_MSG_CHECKING(for type of bool)
 723 AC_ARG_WITH(bool,
 724         [  --with-bool=TYPE        override fallback type of bool variable],
 725         [NCURSES_BOOL="$withval"],
 726         [NCURSES_BOOL=auto])
 727 AC_MSG_RESULT($NCURSES_BOOL)
 728 AC_SUBST(NCURSES_BOOL)
 729
 730 AC_MSG_CHECKING(for alternate terminal capabilities file)
 731 AC_ARG_WITH(caps,
 732         [  --with-caps=alt         compile with alternate Caps file],
 733         [TERMINFO_CAPS=Caps.$withval],
 734         [TERMINFO_CAPS=Caps])
 735 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 736 AC_MSG_RESULT($TERMINFO_CAPS)
 737 AC_SUBST(TERMINFO_CAPS)
 738
 739 ###   use option --with-chtype to override chtype's type
 740 AC_MSG_CHECKING(for type of chtype)
 741 AC_ARG_WITH(chtype,
 742         [  --with-chtype=TYPE      override type of chtype],
 743         [NCURSES_CHTYPE="$withval"],
 744         [NCURSES_CHTYPE=auto])
 745 AC_MSG_RESULT($NCURSES_CHTYPE)
 746
 747 ###   use option --with-ospeed to override ospeed's type
 748 AC_MSG_CHECKING(for type of ospeed)
 749 AC_ARG_WITH(ospeed,
 750         [  --with-ospeed=TYPE      override type of ospeed variable],
 751         [NCURSES_OSPEED="$withval"],
 752         [NCURSES_OSPEED=short])
 753 AC_MSG_RESULT($NCURSES_OSPEED)
 754 AC_SUBST(NCURSES_OSPEED)
 755
 756 ###   use option --with-mmask-t to override mmask_t's type
 757 AC_MSG_CHECKING(for type of mmask_t)
 758 AC_ARG_WITH(mmask-t,
 759         [  --with-mmask-t=TYPE     override type of mmask_t],
 760         [NCURSES_MMASK_T="$withval"],
 761         [NCURSES_MMASK_T=auto])
 762 AC_MSG_RESULT($NCURSES_MMASK_T)
 763
 764 ### Enable compiling-in rcs id's
 765 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
 766 AC_ARG_WITH(rcs-ids,
 767         [  --with-rcs-ids          compile-in RCS identifiers],
 768         [with_rcs_ids=$withval],
 769         [with_rcs_ids=no])
 770 AC_MSG_RESULT($with_rcs_ids)
 771 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
 772
 773 ###############################################################################
 774 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tic toe tput ])
 775
 776 ###############################################################################
 777 CF_HELP_MESSAGE(Extensions:)
 778
 779 ### Note that some functions (such as const) are normally disabled anyway.
 780 AC_MSG_CHECKING(if you want to build with function extensions)
 781 AC_ARG_ENABLE(ext-funcs,
 782         [  --disable-ext-funcs     disable function-extensions],
 783         [with_ext_funcs=$enableval],
 784         [with_ext_funcs=yes])
 785 AC_MSG_RESULT($with_ext_funcs)
 786 if test "$with_ext_funcs" = yes ; then
 787         NCURSES_EXT_FUNCS=1
 788         AC_DEFINE(HAVE_CURSES_VERSION)
 789         AC_DEFINE(HAVE_HAS_KEY)
 790         AC_DEFINE(HAVE_RESIZETERM)
 791         AC_DEFINE(HAVE_RESIZE_TERM)
 792         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
 793         AC_DEFINE(HAVE_WRESIZE)
 794         AC_DEFINE(NCURSES_EXT_FUNCS)
 795 else
 796         NCURSES_EXT_FUNCS=0
 797 fi
 798 AC_SUBST(NCURSES_EXT_FUNCS)
 799
 800 ###   use option --enable-const to turn on use of const beyond that in XSI.
 801 AC_MSG_CHECKING(for extended use of const keyword)
 802 AC_ARG_ENABLE(const,
 803         [  --enable-const          compile with extra/non-standard const],
 804         [with_ext_const=$enableval],
 805         [with_ext_const=no])
 806 AC_MSG_RESULT($with_ext_const)
 807 NCURSES_CONST='/*nothing*/'
 808 if test "$with_ext_const" = yes ; then
 809         NCURSES_CONST=const
 810 fi
 811 AC_SUBST(NCURSES_CONST)
 812
 813 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
 814 AC_ARG_ENABLE(no-padding,
 815         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
 816         [with_no_padding=$enableval],
 817         [with_no_padding=$with_ext_funcs])
 818 AC_MSG_RESULT($with_no_padding)
 819 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
 820
 821 AC_CHECK_SIZEOF([signed char], 0)
 822 if test "$ac_cv_sizeof_signed_char" = 1 ; then
 823         NCURSES_SBOOL="signed char"
 824 else
 825         NCURSES_SBOOL="char"
 826 fi
 827 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
 828 AC_ARG_ENABLE(signed-char,
 829         [  --enable-signed-char    compile using signed Boolean's in term.h],
 830         [with_signed_char=$enableval],
 831         [with_signed_char=no])
 832 AC_MSG_RESULT($with_signed_char)
 833 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
 834 AC_SUBST(NCURSES_SBOOL)
 835
 836 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
 837 AC_MSG_CHECKING(if you want SIGWINCH handler)
 838 AC_ARG_ENABLE(sigwinch,
 839         [  --enable-sigwinch       compile with SIGWINCH handler],
 840         [with_sigwinch=$enableval],
 841         [with_sigwinch=$with_ext_funcs])
 842 AC_MSG_RESULT($with_sigwinch)
 843 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
 844
 845 ###   use option --enable-tcap-names to allow user to define new capabilities
 846 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
 847 AC_ARG_ENABLE(tcap-names,
 848         [  --enable-tcap-names     compile with user-definable terminal capabilities],
 849         [with_tcap_names=$enableval],
 850         [with_tcap_names=$with_ext_funcs])
 851 AC_MSG_RESULT($with_tcap_names)
 852 NCURSES_XNAMES=0
 853 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
 854 AC_SUBST(NCURSES_XNAMES)
 855
 856 ###############################################################################
 857 # These options are relatively safe to experiment with.
 858 CF_HELP_MESSAGE(Development Code:)
 859 AC_MSG_CHECKING(if you want all development code)
 860 AC_ARG_WITH(develop,
 861         [  --without-develop       disable development options],
 862         [with_develop=$withval],
 863         [with_develop=no])
 864 AC_MSG_RESULT($with_develop)
 865
 866 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
 867 AC_MSG_CHECKING(if you want hard-tabs code)
 868 AC_ARG_ENABLE(hard-tabs,
 869         [  --enable-hard-tabs      compile with hard-tabs code],,
 870         [enable_hard_tabs=$with_develop])
 871 AC_MSG_RESULT($enable_hard_tabs)
 872 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
 873
 874 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
 875 AC_MSG_CHECKING(if you want limited support for xmc)
 876 AC_ARG_ENABLE(xmc-glitch,
 877         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
 878         [enable_xmc_glitch=$with_develop])
 879 AC_MSG_RESULT($enable_xmc_glitch)
 880 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
 881
 882 ###############################################################################
 883 # These are just experimental, probably should not be in a package:
 884 CF_HELP_MESSAGE(Experimental Code:)
 885
 886 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
 887 AC_ARG_ENABLE(assumed-color,
 888         [  --disable-assumed-color do not assume anything about default-colors],
 889         [with_assumed_color=$enableval],
 890         [with_assumed_color=yes])
 891 AC_MSG_RESULT($with_assumed_color)
 892 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
 893
 894 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
 895 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
 896 AC_ARG_ENABLE(hashmap,
 897         [  --disable-hashmap       compile without hashmap scrolling-optimization],
 898         [with_hashmap=$enableval],
 899         [with_hashmap=yes])
 900 AC_MSG_RESULT($with_hashmap)
 901 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
 902
 903 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
 904 AC_MSG_CHECKING(if you want colorfgbg code)
 905 AC_ARG_ENABLE(colorfgbg,
 906         [  --enable-colorfgbg      compile with $COLORFGBG code],
 907         [with_colorfgbg=$enableval],
 908         [with_colorfgbg=no])
 909 AC_MSG_RESULT($with_colorfgbg)
 910 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
 911
 912 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
 913 AC_MSG_CHECKING(if you want to use experimental extended colors)
 914 AC_ARG_ENABLE(ext-colors,
 915         [  --enable-ext-colors     compile for experimental 256-color support],
 916         [with_ext_colors=$enableval],
 917         [with_ext_colors=no])
 918 AC_MSG_RESULT($with_ext_colors)
 919 NCURSES_EXT_COLORS=0
 920 if test "$with_ext_colors" = yes ; then
 921         if test "$with_widec" != yes ; then
 922                 AC_MSG_WARN(This option applies only to wide-character library)
 923         else
 924                 # cannot be ABI 5 since it changes sizeof(cchar_t)
 925                 CF_NCURSES_ABI_6
 926         fi
 927         NCURSES_EXT_COLORS=1
 928         AC_DEFINE(NCURSES_EXT_COLORS)
 929 fi
 930 AC_SUBST(NCURSES_EXT_COLORS)
 931
 932 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
 933 AC_MSG_CHECKING(if you want to use experimental extended mouse encoding)
 934 AC_ARG_ENABLE(ext-mouse,
 935         [  --enable-ext-mouse      compile for experimental mouse-encoding],
 936         [with_ext_mouse=$enableval],
 937         [with_ext_mouse=no])
 938 AC_MSG_RESULT($with_ext_mouse)
 939 NCURSES_MOUSE_VERSION=1
 940 if test "$with_ext_mouse" = yes ; then
 941         NCURSES_MOUSE_VERSION=2
 942         CF_NCURSES_ABI_6
 943 fi
 944 AC_SUBST(NCURSES_MOUSE_VERSION)
 945
 946 # Reentrant code has to be opaque; there's little advantage to making ncurses
 947 # opaque outside of that, so there is no --enable-opaque option.
 948 AC_MSG_CHECKING(if you want experimental reentrant code)
 949 AC_ARG_ENABLE(reentrant,
 950         [  --enable-reentrant      compile with experimental reentrant code],
 951         [with_reentrant=$enableval],
 952         [with_reentrant=no])
 953 AC_MSG_RESULT($with_reentrant)
 954 if test "$with_reentrant" = yes ; then
 955         cf_cv_enable_reentrant=1
 956         cf_cv_enable_opaque="NCURSES_INTERNALS"
 957         NCURSES_OPAQUE=1
 958         NCURSES_SIZE_T=int
 959         LIB_SUFFIX="t${LIB_SUFFIX}"
 960         AC_DEFINE(USE_REENTRANT)
 961         CF_NCURSES_ABI_6
 962 else
 963         cf_cv_enable_reentrant=0
 964         cf_cv_enable_opaque="NCURSES_OPAQUE"
 965         NCURSES_OPAQUE=0
 966         NCURSES_SIZE_T=short
 967 fi
 968 AC_SUBST(cf_cv_enable_reentrant)
 969 AC_SUBST(cf_cv_enable_opaque)
 970 AC_SUBST(NCURSES_OPAQUE)
 971 AC_SUBST(NCURSES_SIZE_T)
 972
 973 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
 974 AC_ARG_ENABLE(safe-sprintf,
 975         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
 976         [with_safe_sprintf=$enableval],
 977         [with_safe_sprintf=no])
 978 AC_MSG_RESULT($with_safe_sprintf)
 979 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
 980
 981 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
 982 # when hashmap is used scroll hints are useless
 983 if test "$with_hashmap" = no ; then
 984 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
 985 AC_ARG_ENABLE(scroll-hints,
 986         [  --disable-scroll-hints  compile without scroll-hints code],
 987         [with_scroll_hints=$enableval],
 988         [with_scroll_hints=yes])
 989 AC_MSG_RESULT($with_scroll_hints)
 990 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
 991 fi
 992
 993 AC_MSG_CHECKING(if you want experimental wgetch-events code)
 994 AC_ARG_ENABLE(wgetch-events,
 995         [  --enable-wgetch-events  compile with experimental wgetch-events code],
 996         [with_wgetch_events=$enableval],
 997         [with_wgetch_events=no])
 998 AC_MSG_RESULT($with_wgetch_events)
 999 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1000
1001 ###############################################################################
1002 CF_HELP_MESSAGE(Testing/development Options:)
1003
1004 ###     use option --disable-echo to suppress full display compiling commands
1005 AC_MSG_CHECKING(if you want to display full commands during build)
1006 AC_ARG_ENABLE(echo,
1007         [  --enable-echo           build: display "compiling" commands (default)],
1008         [with_echo=$enableval],
1009         [with_echo=yes])
1010 if test "$with_echo" = yes; then
1011         ECHO_LINK=
1012 else
1013         ECHO_LINK='@ echo linking $@ ... ;'
1014         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1015 fi
1016 AC_MSG_RESULT($with_echo)
1017 AC_SUBST(ECHO_LINK)
1018
1019 ###     use option --enable-warnings to turn on all gcc warnings
1020 AC_MSG_CHECKING(if you want to see compiler warnings)
1021 AC_ARG_ENABLE(warnings,
1022         [  --enable-warnings       build: turn on GCC compiler warnings],
1023         [with_warnings=$enableval])
1024 AC_MSG_RESULT($with_warnings)
1025
1026 if test -n "$with_warnings"; then
1027         ADAFLAGS="$ADAFLAGS -gnatg"
1028         CF_GCC_WARNINGS
1029         if test "$cf_with_cxx" = yes ; then
1030                 CF_GXX_WARNINGS(Wno-unused)
1031         fi
1032 fi
1033 CF_GCC_ATTRIBUTES
1034
1035 ###     use option --enable-assertions to turn on generation of assertion code
1036 AC_MSG_CHECKING(if you want to enable runtime assertions)
1037 AC_ARG_ENABLE(assertions,
1038         [  --enable-assertions     test: turn on generation of assertion code],
1039         [with_assertions=$enableval],
1040         [with_assertions=no])
1041 AC_MSG_RESULT($with_assertions)
1042 if test -n "$GCC"
1043 then
1044         if test "$with_assertions" = no
1045         then
1046                 AC_DEFINE(NDEBUG)
1047                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1048         else
1049                 ADAFLAGS="$ADAFLAGS -gnata"
1050         fi
1051 fi
1052
1053 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1054 CF_DISABLE_LEAKS
1055 AC_DEFINE(HAVE_NC_ALLOC_H)
1056
1057 ###     use option --enable-expanded to generate certain macros as functions
1058 AC_ARG_ENABLE(expanded,
1059         [  --enable-expanded       test: generate functions for certain macros],
1060         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1061
1062 ###     use option --disable-macros to suppress macros in favor of functions
1063 AC_ARG_ENABLE(macros,
1064         [  --disable-macros        test: use functions rather than macros],
1065         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1066
1067 # Normally we only add trace() to the debug-library.  Allow this to be
1068 # extended to all models of the ncurses library:
1069 cf_all_traces=no
1070 case "$CFLAGS $CPPFLAGS" in
1071 *-DTRACE*)
1072         cf_all_traces=yes
1073         ;;
1074 esac
1075
1076 AC_MSG_CHECKING(whether to add trace feature to all models)
1077 AC_ARG_WITH(trace,
1078 [  --with-trace            test: add trace() function to all models of ncurses],
1079 [cf_with_trace=$withval],
1080 [cf_with_trace=$cf_all_traces])
1081 AC_MSG_RESULT($cf_with_trace)
1082
1083 if test "$cf_with_trace" = yes ; then
1084         LIB_TRACING=all
1085         ADA_TRACE=TRUE
1086         CF_ADD_CFLAGS(-DTRACE)
1087 else
1088         LIB_TRACING=DEBUG
1089         ADA_TRACE=FALSE
1090 fi
1091
1092 AC_SUBST(ADA_TRACE)
1093
1094 ###     Checks for libraries.
1095 AC_CHECK_FUNC(gettimeofday,
1096         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1097
1098 AC_CHECK_LIB(bsd, gettimeofday,
1099         AC_DEFINE(HAVE_GETTIMEOFDAY)
1100         LIBS="$LIBS -lbsd")])dnl CLIX: bzero, select, gettimeofday
1101
1102 CF_MATH_LIB(MATH_LIB,sin(x))
1103 AC_SUBST(MATH_LIB)
1104
1105 ###     Checks for header files.
1106 AC_STDC_HEADERS
1107 AC_HEADER_DIRENT
1108 AC_HEADER_TIME
1109 CF_REGEX
1110
1111 dnl These are some other potentially nonportable headers.
1112 AC_CHECK_HEADERS( \
1113 fcntl.h \
1114 getopt.h \
1115 limits.h \
1116 locale.h \
1117 poll.h \
1118 sys/bsdtypes.h \
1119 sys/ioctl.h \
1120 sys/param.h \
1121 sys/poll.h \
1122 sys/select.h \
1123 sys/time.h \
1124 sys/times.h \
1125 ttyent.h \
1126 unistd.h \
1127 wctype.h \
1128 )
1129
1130 # check for ISC (this may also define _POSIX_SOURCE)
1131 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1132 if test "$ISC" = yes ; then
1133         AC_CHECK_LIB(cposix,main)
1134         AC_CHECK_LIB(inet,bzero,LIBS="$LIBS -linet")dnl also 'select()'
1135 fi
1136
1137 CF_SYS_TIME_SELECT
1138
1139 ###     checks for compiler characteristics
1140 AC_LANG_C
1141 AC_C_CONST
1142 AC_C_INLINE
1143
1144 NCURSES_INLINE=
1145 if test "$ac_cv_c_inline" != no ; then
1146         AC_DEFINE(CC_HAS_INLINE_FUNCS)
1147         NCURSES_INLINE=inline
1148 fi
1149 AC_SUBST(NCURSES_INLINE)
1150
1151 if test $NCURSES_CHTYPE = auto ; then
1152         CF_TYPEOF_CHTYPE
1153 else
1154         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1155 fi
1156 AC_SUBST(cf_cv_typeof_chtype)
1157
1158 CF_UNSIGNED_LITERALS
1159 cf_cv_1UL="1"
1160 test "$cf_cv_unsigned_literals" = yes && cf_cv_1UL="${cf_cv_1UL}U"
1161 test "$cf_cv_typeof_chtype"    = long && cf_cv_1UL="${cf_cv_1UL}L"
1162 AC_SUBST(cf_cv_1UL)
1163
1164 if test $NCURSES_MMASK_T = auto ; then
1165         cf_cv_typeof_mmask_t=long
1166 else
1167         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1168 fi
1169 AC_SUBST(cf_cv_typeof_mmask_t)
1170
1171 ###     Checks for external-data
1172 CF_ERRNO
1173 CF_LINK_DATAONLY
1174
1175 ###     Checks for library functions.
1176 AC_CHECK_FUNCS( \
1177 getcwd \
1178 getegid \
1179 geteuid \
1180 getttynam \
1181 issetugid \
1182 poll \
1183 remove \
1184 select \
1185 setbuf \
1186 setbuffer \
1187 setvbuf \
1188 sigaction \
1189 sigvec \
1190 strdup \
1191 strstr \
1192 tcgetpgrp \
1193 times \
1194 vsnprintf \
1195 )
1196 if test "$with_getcap" = "yes" ; then
1197         CF_CGETENT
1198 fi
1199
1200 CF_ISASCII
1201 CF_STRUCT_SIGACTION
1202 CF_FUNC_NANOSLEEP
1203 CF_FUNC_TERMIOS
1204 CF_FUNC_VSSCANF
1205 CF_MKSTEMP
1206
1207 # setup for prototype of fallback for vsscanf()
1208 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1209
1210 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1211 if test "$cross_compiling" = yes ; then
1212         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1213 else
1214         AC_FUNC_SETVBUF_REVERSED
1215 fi
1216 AC_TYPE_SIGNAL
1217 CF_TYPE_SIGACTION
1218 CF_SIZECHANGE
1219 CF_FUNC_MEMMOVE
1220 CF_FUNC_POLL
1221
1222 if test "$with_hashed_db" != no ; then
1223         AC_DEFINE(USE_HASHED_DB)
1224         CF_HASHED_DB
1225 fi
1226
1227 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1228 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1229         CF_STRIP_G_OPT(CFLAGS)
1230         CF_STRIP_G_OPT(CXXFLAGS)
1231 fi
1232
1233 # Just in case, check if the C compiler has a bool type.
1234 CF_BOOL_DECL(cf_cv_cc_bool_type)
1235
1236 # Check for C++ compiler characteristics (and ensure that it's there!)
1237 if test -n "$CXX" ; then
1238         AC_LANG_CPLUSPLUS
1239         CF_STDCPP_LIBRARY
1240         CF_PROG_CC_C_O(CXX)
1241
1242         case $GXX_VERSION in
1243         1*|2.[0-6]*)
1244                 cf_cxx_library=yes
1245                 ;;
1246         *-2.7*|2.7*)
1247                 CF_GPP_LIBRARY
1248                 ;;
1249         *)
1250                 cf_cxx_library=no
1251                 ;;
1252         esac
1253
1254         AC_CHECK_HEADERS(typeinfo)
1255
1256         CF_BOOL_DECL
1257         CF_BOOL_SIZE
1258         CF_ETIP_DEFINES
1259         CF_CPP_PARAM_INIT
1260         CF_CPP_STATIC_CAST
1261
1262         CXX_AR='$(AR)'
1263         CXX_AR_OPTS='$(AR_OPTS)'
1264         case $cf_cv_system_name in #(vi
1265         irix*) #(vi
1266             if test "$GXX" != yes ; then
1267                 CXX_AR='$(CXX)'
1268                 CXX_AR_OPTS='-ar -o'
1269             fi
1270             ;;
1271         sco3.2v5*) #(vi
1272             CXXLDFLAGS="-u main"
1273             ;;
1274         solaris2*)
1275             if test "$GXX" != yes ; then
1276                 CXX_AR='$(CXX)'
1277                 CXX_AR_OPTS='-xar -o'
1278             fi
1279             ;;
1280         esac
1281         AC_SUBST(CXXLDFLAGS)
1282         AC_SUBST(CXX_AR)
1283         AC_SUBST(CXX_AR_OPTS)
1284 else
1285         cf_cxx_library=no
1286         cf_cv_builtin_bool=1
1287
1288         # Just because we are not configuring against C++ right now does not
1289         # mean that a user will not want to use C++.  Some distributors disable
1290         # the C++ portion of this configuration as a shortcut (or just to avoid
1291         # compiling the demo in the c++ directory).  So we need a reasonable
1292         # default for the 'bool' type.
1293         #
1294         # Caveat: since the storage of the bool type is not standardized, it
1295         # may change.
1296
1297         if test "$NCURSES_BOOL" != auto ; then
1298                 cf_cv_type_of_bool=$NCURSES_BOOL
1299                 cf_cv_header_stdbool_h=0
1300         else
1301                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1302                         CF_BOOL_SIZE
1303                 else
1304                         AC_MSG_CHECKING(for fallback type of bool)
1305                         case "$host_cpu" in #(vi
1306                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1307                         *)      cf_cv_type_of_bool=int  ;;
1308                         esac
1309                         AC_MSG_RESULT($cf_cv_type_of_bool)
1310                 fi
1311         fi
1312 fi
1313 AC_SUBST(CXXLIBS)
1314
1315 # If the C compiler did not declare bool, and we did not determine that the C++
1316 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1317 # ncurses library use the same type as C++ bool.  Note that this allows one to
1318 # specify the type of bool in a configure-script option and postpone
1319 # integration with the C++ compiler provided that the types are compatible.
1320 USE_CXX_BOOL=1
1321 if test $cf_cv_cc_bool_type = 1
1322 then
1323         # oops: C has a bool.  Unlikely, but C++ could differ.
1324         USE_CXX_BOOL=0
1325 elif test $cf_cv_builtin_bool = 0
1326 then
1327         # C++ has no bool
1328         USE_CXX_BOOL=0
1329 else
1330         # this is the normal case
1331         USE_CXX_BOOL='defined(__cplusplus)'
1332 fi
1333 AC_SUBST(USE_CXX_BOOL)
1334
1335 CF_HELP_MESSAGE(Ada95 Binding Options:)
1336
1337 dnl Check for availability of GNU Ada Translator (GNAT).
1338 dnl At the moment we support no other Ada95 compiler.
1339 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1340 if test "$cf_with_ada" != "no" ; then
1341 cf_ada_make=gnatmake
1342 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
1343 if test "$ac_cv_prog_gnat_exists" = no; then
1344    cf_ada_make=
1345 else
1346    CF_GNAT_VERSION
1347    AC_CHECK_PROG(M4_exists, m4, yes, no)
1348    if test "$ac_cv_prog_M4_exists" = no; then
1349       cf_cv_prog_gnat_correct=no
1350       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
1351    fi
1352    if test "$cf_cv_prog_gnat_correct" = yes; then
1353       AC_MSG_CHECKING(if GNAT works)
1354       CF_GNAT_TRY_RUN([procedure conftest;],
1355 [with Text_IO;
1356 with GNAT.OS_Lib;
1357 procedure conftest is
1358 begin
1359    Text_IO.Put ("Hello World");
1360    Text_IO.New_Line;
1361    GNAT.OS_Lib.OS_Exit (0);
1362 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
1363       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
1364    fi
1365 fi
1366 if test "$cf_cv_prog_gnat_correct" = yes; then
1367    ADAFLAGS="-O3 -gnatpn $ADAFLAGS"
1368
1369    AC_MSG_CHECKING(if GNAT pragma Unreferenced works)
1370    CF_GNAT_TRY_LINK([procedure conftest;],
1371 [with Text_IO;
1372 with GNAT.OS_Lib;
1373 procedure conftest is
1374    test : Integer;
1375    pragma Unreferenced (test);
1376 begin
1377    test := 1;
1378    Text_IO.Put ("Hello World");
1379    Text_IO.New_Line;
1380    GNAT.OS_Lib.OS_Exit (0);
1381 end conftest;],[cf_cv_pragma_unreferenced=yes],[cf_cv_pragma_unreferenced=no])
1382    AC_MSG_RESULT($cf_cv_pragma_unreferenced)
1383
1384    # if the pragma is supported, use it (needed in the Trace code).
1385    if test $cf_cv_pragma_unreferenced = yes ; then
1386       PRAGMA_UNREF=TRUE
1387    else
1388       PRAGMA_UNREF=FALSE
1389    fi
1390
1391    AC_ARG_WITH(ada-compiler,
1392         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
1393         [cf_ada_compiler=$withval],
1394         [cf_ada_compiler=gnatmake])
1395
1396    cf_ada_package=terminal_interface
1397
1398    AC_SUBST(cf_ada_make)
1399    AC_SUBST(cf_ada_compiler)
1400    AC_SUBST(cf_ada_package)
1401    AC_SUBST(ADAFLAGS)
1402    AC_SUBST(cf_compile_generics)
1403    AC_SUBST(cf_generic_objects)
1404    AC_SUBST(PRAGMA_UNREF)
1405
1406    CF_WITH_PATH(ada-include,
1407        [  --with-ada-include=DIR  Ada includes are in DIR],
1408        ADA_INCLUDE,
1409        PREFIX/lib/ada/adainclude,
1410        [$]prefix/lib/ada/adainclude)
1411    AC_SUBST(ADA_INCLUDE)
1412
1413    CF_WITH_PATH(ada-objects,
1414        [  --with-ada-objects=DIR  Ada objects are in DIR],
1415        ADA_OBJECTS,
1416        PREFIX/lib/ada/adalib,
1417        [$]prefix/lib/ada/adalib)
1418    AC_SUBST(ADA_OBJECTS)
1419
1420 fi
1421 fi
1422 fi
1423
1424 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1425 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1426 ###
1427 ### ticlib modules may be a separate library, otherwise contained in termlib.
1428 ### termlib modules may be a separate library, otherwise contained in ncurses.
1429 ###
1430 ### The of "+" or " " between the tokens controls the way the script
1431 ### chooses to split module lists into libraries.
1432 ###
1433 ### (see CF_LIB_RULES).
1434 AC_MSG_CHECKING(for library subsets)
1435 LIB_SUBSETS=
1436
1437 if test "$cf_with_progs" = yes || test "$with_ticlib" != no; then
1438         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1439         if test "$with_ticlib" != no ; then
1440                 LIB_SUBSETS="${LIB_SUBSETS} "
1441         else
1442                 LIB_SUBSETS="${LIB_SUBSETS}+"
1443         fi
1444 fi
1445
1446 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1447 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1448 if test "$with_termlib" != no ; then
1449         LIB_SUBSETS="${LIB_SUBSETS} "
1450 else
1451         LIB_SUBSETS="${LIB_SUBSETS}+"
1452 fi
1453
1454 LIB_SUBSETS="${LIB_SUBSETS}base"
1455 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1456 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1457
1458 AC_MSG_RESULT($LIB_SUBSETS)
1459
1460 ### Construct the list of include-directories to be generated
1461 CF_INCLUDE_DIRS
1462 CF_ADA_INCLUDE_DIRS
1463
1464 ### Build up pieces for makefile rules
1465 AC_MSG_CHECKING(default library suffix)
1466 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1467 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1468 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1469
1470 AC_MSG_CHECKING(default library-dependency suffix)
1471 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_DEP_SUFFIX)dnl
1472 if test $DFT_LWR_MODEL = shared ; then
1473         case $cf_cv_system_name in #(vi
1474         cygwin*)
1475                 DFT_DEP_SUFFIX=".dll.a"
1476                 ;;
1477         esac
1478 fi
1479 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1480 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1481
1482 AC_MSG_CHECKING(default object directory)
1483 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1484 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1485 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1486
1487 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1488 if test "$cf_with_cxx" = yes ; then
1489 AC_MSG_CHECKING(c++ library-dependency suffix)
1490 if test "$with_libtool" != "no"; then
1491         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1492 else
1493         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX)dnl we normally make a static library
1494 fi
1495 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1496 AC_SUBST(CXX_LIB_SUFFIX)
1497 fi
1498
1499 # do not want -ldl in build except as needed for -lncurses dependency
1500 if test "$with_dlsym" = yes ; then
1501 if test $DFT_LWR_MODEL = shared || \
1502    test $DFT_LWR_MODEL = libtool ; then
1503         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1504 fi
1505 fi
1506 ### Set up low-level terminfo dependencies for makefiles.
1507
1508 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1509 # do not need libdl
1510 TICS_LIST=
1511 if test "$with_dlsym" = yes ; then
1512         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1513 fi
1514
1515 if test "$with_ticlib" != no ; then
1516
1517         if test "$with_ticlib" != yes ; then
1518                 TICS_NAME=$with_ticlib
1519                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1520                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1521                 TICS_LIB_SUFFIX="${with_ticlib}"
1522         else
1523                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1524                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1525                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1526         fi
1527         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1528 else
1529         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1530 fi
1531 AC_SUBST(TICS_ARG_SUFFIX)
1532 AC_SUBST(TICS_DEP_SUFFIX)
1533 AC_SUBST(TICS_LIB_SUFFIX)
1534 AC_SUBST(TICS_ARGS)
1535
1536 if test "$with_termlib" != no ; then
1537
1538         if test "$with_termlib" != yes ; then
1539                 TINFO_NAME=$with_termlib
1540                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1541                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1542                 TINFO_LIB_SUFFIX="${with_termlib}"
1543         else
1544                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1545                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1546                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1547         fi
1548
1549         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1550         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1551         if test "$DFT_LWR_MODEL" = "libtool"; then
1552                 TEST_ARGS="${TEST_DEPS}"
1553                 TEST_ARG2="${TEST_DEP2}"
1554                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1555         else
1556                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1557                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1558                 TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1559                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1560                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1561         fi
1562 else
1563         # the next lines are needed for linking libtic over libncurses
1564         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1565         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1566
1567         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1568 fi
1569 AC_SUBST(TINFO_ARG_SUFFIX)
1570 AC_SUBST(TINFO_DEP_SUFFIX)
1571 AC_SUBST(TINFO_LIB_SUFFIX)
1572 AC_SUBST(TINFO_ARGS)
1573
1574 if test "$with_dlsym" = yes ; then
1575         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1576 fi
1577
1578 # needed for Ada95
1579 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1580 AC_SUBST(TINFO_ARGS2)
1581
1582 AC_MSG_CHECKING(where we will install curses.h)
1583 test "$with_overwrite" = no && \
1584 test "x$includedir" = 'x${prefix}/include' && \
1585         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1586 AC_MSG_RESULT($includedir)
1587
1588 ### Resolve a conflict between normal and wide-curses by forcing applications
1589 ### that will need libutf8 to add it to their configure script.
1590 if test "$with_overwrite" != no ; then
1591 if test "$NCURSES_LIBUTF8" = 1 ; then
1592         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1593         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1594 fi
1595 fi
1596
1597 AC_SUBST(WITH_OVERWRITE)
1598 AC_SUBST(TICS_LIST)
1599 AC_SUBST(TINFO_LIST)
1600 AC_SUBST(SHLIB_LIST)
1601
1602 # used to separate tack out of the tree
1603 NCURSES_TREE=
1604 AC_SUBST(NCURSES_TREE)
1605
1606 ### predefined stuff for the test programs
1607 AC_DEFINE(HAVE_SLK_COLOR)
1608
1609 ### Construct the list of subdirectories for which we'll customize makefiles
1610 ### with the appropriate compile-rules.
1611
1612 CF_SRC_MODULES($modules_to_build)
1613 CF_DIRS_TO_MAKE
1614
1615 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATHSEP')
1616
1617 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1618
1619 ### Now that we're done running tests, add the compiler-warnings, if any
1620 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1621
1622 ### Define substitutions for header files to avoid name-pollution
1623 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1624 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1625 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1626
1627 ################################################################################
1628 test "$use_database" = yes && SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1629 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1630 AC_OUTPUT( \
1631         include/MKterm.h.awk \
1632         include/curses.head:include/curses.h.in \
1633         include/termcap.h \
1634         include/unctrl.h \
1635         $SUB_MAKEFILES \
1636         Makefile,[
1637 CF_PRG_RULES([$srcdir/test/mk-test.awk ECHO_LINK="$ECHO_LINK"], test)
1638 CF_LIB_RULES($SRC_SUBDIRS)
1639 ],[
1640 ### Special initialization commands, used to pass information from the
1641 ### configuration-run into config.status
1642
1643 AWK="$AWK"
1644 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1645 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1646 ECHO_LINK="$ECHO_LINK"
1647 LDCONFIG="$LDCONFIG"
1648 LIB_NAME="$LIB_NAME"
1649 LIB_SUBSETS="$LIB_SUBSETS"
1650 LIB_SUFFIX="$LIB_SUFFIX"
1651 LIB_TRACING="$LIB_TRACING"
1652 MAKE_TERMINFO="$MAKE_TERMINFO"
1653 NCURSES_MAJOR="$NCURSES_MAJOR"
1654 NCURSES_MINOR="$NCURSES_MINOR"
1655 NCURSES_OSPEED="$NCURSES_OSPEED"
1656 NCURSES_PATCH="$NCURSES_PATCH"
1657 SRC_SUBDIRS="$SRC_SUBDIRS"
1658 TERMINFO="$TERMINFO"
1659 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1660 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1661 TINFO_NAME="$TINFO_NAME"
1662 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1663 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1664 TICS_NAME="$TICS_NAME"
1665 WITH_CURSES_H="$with_curses_h"
1666 WITH_ECHO="$with_echo"
1667 WITH_OVERWRITE="$with_overwrite"
1668 cf_LIST_MODELS="$cf_list_models"
1669 cf_cv_abi_version="$cf_cv_abi_version"
1670 cf_cv_do_relink="$cf_cv_do_relink"
1671 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1672 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1673 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1674 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1675 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1676 cf_cv_rel_version="$cf_cv_rel_version"
1677 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1678 cf_cv_shlib_version="$cf_cv_shlib_version"
1679 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1680 cf_cv_system_name="$cf_cv_system_name"
1681 cf_with_cxx_binding="$cf_with_cxx_binding"
1682 host="$host"
1683 target="$target"
1684
1685 ],cat)dnl
1686 ${MAKE-make} preinstall