configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2011,2012 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.539 2012/01/22 01:08:15 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.13.20020210)
  38 AC_REVISION($Revision: 1.539 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44
  45 CF_WITH_REL_VERSION(NCURSES)
  46 CF_WITH_ABI_VERSION
  47
  48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
  49 AC_ARG_WITH(system-type,
  50 [  --with-system-type=XXX  test: override derived host system-type],
  51 [AC_MSG_WARN(overriding system type to $withval)
  52  cf_cv_system_name=$withval])
  53
  54 ###     Save the given $CFLAGS to allow user-override.
  55 cf_user_CFLAGS="$CFLAGS"
  56
  57 ###     Default install-location
  58 CF_CFG_DEFAULTS
  59
  60 ###     Checks for programs.
  61 AC_PROG_CC
  62 CF_GCC_VERSION
  63
  64 AC_PROG_CPP
  65 AC_PROG_GCC_TRADITIONAL
  66 CF_PROG_CC_C_O(CC)
  67 AC_ISC_POSIX
  68 CF_ANSI_CC_REQD
  69 CF_PROG_EXT
  70 CF_PROG_LDCONFIG
  71
  72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  73 dnl                             configure script by not letting us test if C++
  74 dnl                             is present, making this option necessary.
  75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  76 AC_ARG_WITH(cxx,
  77         [  --without-cxx           do not adjust ncurses bool to match C++],
  78         [cf_with_cxx=$withval],
  79         [cf_with_cxx=yes])
  80 AC_MSG_RESULT($cf_with_cxx)
  81 if test "X$cf_with_cxx" = Xno ; then
  82         CXX=""
  83         GXX=""
  84 else
  85         # with autoconf 2.13, we can change the error to a warning:
  86         pushdef([AC_MSG_ERROR],
  87                 [AC_MSG_RESULT(no)
  88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  90         AC_PROG_CXX
  91         popdef([AC_MSG_ERROR])dnl
  92         # autoconf 2.5x removed the error - by hardcoding it to g++.
  93         if test "$CXX" = "g++" ; then
  94                 AC_PATH_PROG(CXX,g++)
  95         fi
  96         if test "$CXX" = "g++" ; then
  97                 AC_MSG_WARN(ignoring hardcoded g++)
  98                 cf_with_cxx=no; CXX=""; GXX="";
  99         fi
 100 fi
 101
 102 CF_GXX_VERSION
 103 case $GXX_VERSION in
 104 1*|2.[[0-6]]*)
 105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 106         # cf_cxx_library=no
 107         AC_MSG_WARN(templates do not work)
 108         ;;
 109 esac
 110
 111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 112 AC_ARG_WITH(cxx-binding,
 113         [  --without-cxx-binding   do not build C++ binding and demo],
 114         [cf_with_cxx_binding=$withval],
 115         [cf_with_cxx_binding=$cf_with_cxx])
 116 AC_MSG_RESULT($cf_with_cxx_binding)
 117
 118 AC_MSG_CHECKING(if you want to build with Ada95)
 119 AC_ARG_WITH(ada,
 120         [  --without-ada           suppress check for Ada95, don't build demo],
 121         [cf_with_ada=$withval],
 122         [cf_with_ada=yes])
 123 AC_MSG_RESULT($cf_with_ada)
 124
 125 AC_MSG_CHECKING(if you want to install manpages)
 126 AC_ARG_WITH(manpages,
 127         [  --without-manpages      suppress install of manpages],
 128         [cf_with_manpages=$withval],
 129         [cf_with_manpages=yes])
 130 AC_MSG_RESULT($cf_with_manpages)
 131
 132 AC_MSG_CHECKING(if you want to build programs such as tic)
 133 AC_ARG_WITH(progs,
 134         [  --without-progs         suppress build with programs (e.g., tic)],
 135         [cf_with_progs=$withval],
 136         [cf_with_progs=yes])
 137 AC_MSG_RESULT($cf_with_progs)
 138
 139 AC_MSG_CHECKING(if you want to build test-programs)
 140 AC_ARG_WITH(tests,
 141         [  --without-tests         suppress build with test-programs],
 142         [cf_with_tests=$withval],
 143         [cf_with_tests=yes])
 144 AC_MSG_RESULT($cf_with_tests)
 145
 146 AC_MSG_CHECKING(if you wish to install curses.h)
 147 AC_ARG_WITH(curses-h,
 148         [  --without-curses-h      install curses.h as ncurses.h only],
 149         [with_curses_h=$withval],
 150         [with_curses_h=yes])
 151 AC_MSG_RESULT($with_curses_h)
 152
 153 modules_to_build="ncurses"
 154 if test "X$cf_with_progs" != Xno ; then
 155 modules_to_build="$modules_to_build progs tack"
 156 fi
 157 modules_to_build="$modules_to_build panel menu form"
 158
 159 AC_ARG_PROGRAM
 160
 161 CF_PROG_AWK
 162 CF_PROG_EGREP
 163 CF_PROG_INSTALL
 164 CF_PROG_LINT
 165 CF_PROG_LN_S
 166
 167 AC_SYS_LONG_FILE_NAMES
 168
 169 # if we find pkg-config, check if we should install the ".pc" files.
 170 CF_PKG_CONFIG
 171 CF_WITH_PKG_CONFIG_LIBDIR
 172 CF_ENABLE_PC_FILES
 173
 174 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 175 AC_ARG_ENABLE(mixed-case,
 176         [  --enable-mixed-case     tic should assume mixed-case filenames],
 177         [enable_mixedcase=$enableval],
 178         [enable_mixedcase=auto])
 179 AC_MSG_RESULT($enable_mixedcase)
 180 if test "$enable_mixedcase" = "auto" ; then
 181     CF_MIXEDCASE_FILENAMES
 182 else
 183     cf_cv_mixedcase=$enable_mixedcase
 184     if test "$enable_mixedcase" = "yes" ; then
 185         AC_DEFINE(MIXEDCASE_FILENAMES)
 186     fi
 187 fi
 188
 189 # do this after mixed-case option (tags/TAGS is not as important as tic).
 190 AC_PROG_MAKE_SET
 191 CF_MAKE_TAGS
 192 CF_MAKEFLAGS
 193
 194 dnl These are standard among *NIX systems, but not when cross-compiling
 195 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 196 AC_CHECK_TOOL(LD, ld, ld)
 197 AC_CHECK_TOOL(AR, ar, ar)
 198 CF_AR_FLAGS
 199
 200 dnl Special option for use by system-builders: the install-prefix is used to
 201 dnl adjust the location into which the actual install is done, so that an
 202 dnl archive can be built without modifying the host system's configuration.
 203 AC_MSG_CHECKING(if you have specified an install-prefix)
 204 AC_ARG_WITH(install-prefix,
 205         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 206         [case "$withval" in #(vi
 207         yes|no) #(vi
 208                 ;;
 209         *)      DESTDIR="$withval"
 210                 ;;
 211         esac])
 212 AC_MSG_RESULT($DESTDIR)
 213 AC_SUBST(DESTDIR)
 214
 215 ###############################################################################
 216 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 217 # If we're cross-compiling, allow the user to override the tools and their
 218 # options.  The configure script is oriented toward identifying the host
 219 # compiler, etc., but we need a build compiler to generate parts of the source.
 220 CF_BUILD_CC
 221
 222 ###############################################################################
 223 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 224
 225 ### Options to allow the user to specify the set of libraries which are used.
 226 ### Use "--without-normal --with-shared" to allow the default model to be
 227 ### shared, for example.
 228 cf_list_models=""
 229 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 230
 231 CF_WITH_LIBTOOL
 232 if test "$with_libtool" != "no" ; then
 233
 234 cf_list_models="$cf_list_models libtool"
 235
 236 else
 237
 238 AC_MSG_CHECKING(if you want to build shared libraries)
 239 AC_ARG_WITH(shared,
 240         [  --with-shared           generate shared-libraries],
 241         [with_shared=$withval],
 242         [with_shared=no])
 243 AC_MSG_RESULT($with_shared)
 244 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
 245
 246 AC_MSG_CHECKING(if you want to build static libraries)
 247 AC_ARG_WITH(normal,
 248         [  --with-normal           generate normal-libraries (default)],
 249         [with_normal=$withval],
 250         [with_normal=yes])
 251 AC_MSG_RESULT($with_normal)
 252 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
 253
 254 AC_MSG_CHECKING(if you want to build debug libraries)
 255 AC_ARG_WITH(debug,
 256         [  --with-debug            generate debug-libraries (default)],
 257         [with_debug=$withval],
 258         [with_debug=yes])
 259 AC_MSG_RESULT($with_debug)
 260 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
 261
 262 AC_MSG_CHECKING(if you want to build profiling libraries)
 263 AC_ARG_WITH(profile,
 264         [  --with-profile          generate profile-libraries],
 265         [with_profile=$withval],
 266         [with_profile=no])
 267 AC_MSG_RESULT($with_profile)
 268 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
 269
 270 fi
 271
 272 ###############################################################################
 273
 274 AC_MSG_CHECKING(for specified models)
 275 test -z "$cf_list_models" && cf_list_models=normal
 276 dnl If we use libtool to generate libraries, then it must be the only
 277 dnl specified model.
 278 test "$with_libtool" != "no" && cf_list_models=libtool
 279 AC_MSG_RESULT($cf_list_models)
 280
 281 ### Use the first model as the default, and save its suffix for use in building
 282 ### up test-applications.
 283 AC_MSG_CHECKING(for default model)
 284 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 285 AC_MSG_RESULT($DFT_LWR_MODEL)
 286
 287 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 288
 289 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 290 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 291
 292 TICS_NAME=tic
 293 AC_SUBST(TICS_NAME)
 294
 295 TINFO_NAME=tinfo
 296 AC_SUBST(TINFO_NAME)
 297
 298 LIB_NAME=ncurses
 299 AC_SUBST(LIB_NAME)
 300
 301 LIB_DIR=../lib
 302 LIB_2ND=../../lib
 303
 304 CF_WITH_LIB_PREFIX(cf_prefix)
 305
 306 LIB_SUFFIX=
 307 AC_SUBST(LIB_SUFFIX)
 308
 309 ###############################################################################
 310
 311 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 312 AC_ARG_WITH(termlib,
 313         [  --with-termlib          generate separate terminfo library],
 314         [with_termlib=$withval],
 315         [with_termlib=no])
 316 AC_MSG_RESULT($with_termlib)
 317
 318 AC_MSG_CHECKING(if you want to build a separate tic library)
 319 AC_ARG_WITH(ticlib,
 320         [  --with-ticlib           generate separate tic library],
 321         [with_ticlib=$withval],
 322         [with_ticlib=no])
 323 AC_MSG_RESULT($with_ticlib)
 324
 325 ### Checks for special libraries, must be done up-front.
 326 SHLIB_LIST=""
 327 CF_WITH_GPM
 328 if test "$with_gpm" != no ; then
 329         AC_MSG_CHECKING(if you want to load GPM dynamically)
 330         AC_ARG_WITH(dlsym,
 331                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 332                 [with_dlsym=$withval],
 333                 [with_dlsym=yes])
 334         AC_MSG_RESULT($with_dlsym)
 335         if test "$with_dlsym" = yes ; then
 336                 CF_FUNC_DLSYM
 337                 if test "$with_gpm" != yes ; then
 338                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 339                         cf_cv_gpm_soname="$with_gpm"
 340                 else
 341                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 342                 fi
 343                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
 344                 SHLIB_LIST="-ldl $SHLIB_LIST"
 345         else
 346                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 347                 CF_ADD_LIB(gpm,TEST_LIBS)
 348         fi
 349         AC_DEFINE(HAVE_LIBGPM)
 350         CF_CHECK_GPM_WGETCH
 351 fi
 352
 353 CF_WITH_SYSMOUSE
 354
 355 dnl Not all ports of gcc support the -g option
 356
 357 if test X"$CC_G_OPT" = X"" ; then
 358         CC_G_OPT='-g'
 359         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
 360 fi
 361 AC_SUBST(CC_G_OPT)
 362
 363 if test X"$CXX_G_OPT" = X"" ; then
 364         CXX_G_OPT='-g'
 365         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
 366 fi
 367 AC_SUBST(CXX_G_OPT)
 368
 369 AC_MSG_CHECKING(for default loader flags)
 370 case $DFT_LWR_MODEL in
 371 libtool) LD_MODEL=''   ;;
 372 normal)  LD_MODEL=''   ;;
 373 debug)   LD_MODEL=$CC_G_OPT ;;
 374 profile) LD_MODEL='-pg';;
 375 shared)  LD_MODEL=''   ;;
 376 esac
 377 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 378 AC_MSG_RESULT($LD_MODEL)
 379
 380 case $DFT_LWR_MODEL in
 381 shared)
 382 CF_ENABLE_RPATH
 383 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 384 AC_ARG_ENABLE(relink,
 385 [  --disable-relink        relink shared libraries during install],
 386 [cf_cv_do_relink=$enableval],
 387 [cf_cv_do_relink=yes])
 388 AC_MSG_RESULT($cf_cv_do_relink)
 389         ;;
 390 esac
 391
 392 CF_SHARED_OPTS
 393 if test "$CC_SHARED_OPTS" = "unknown"; then
 394         for model in $cf_list_models; do
 395                 if test "$model" = "shared"; then
 396                         AC_ERROR(Shared libraries are not supported in this version)
 397                 fi
 398         done
 399 fi
 400
 401 ### If we're building with rpath, try to link non-standard libs that way too.
 402 if test "$DFT_LWR_MODEL" = "shared"; then
 403         CF_DISABLE_RPATH_HACK
 404 fi
 405
 406 ###############################################################################
 407 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 408
 409 ###     use option --disable-overwrite to leave out the link to -lcurses
 410 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 411 AC_ARG_ENABLE(overwrite,
 412         [  --disable-overwrite     leave out the link to -lcurses],
 413         [with_overwrite=$enableval],
 414         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 415 AC_MSG_RESULT($with_overwrite)
 416
 417 AC_MSG_CHECKING(if external terminfo-database is used)
 418 AC_ARG_ENABLE(database,
 419         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 420         [use_database=$enableval],
 421         [use_database=yes])
 422 AC_MSG_RESULT($use_database)
 423
 424 case $host_os in #(vi
 425 os2*) #(vi
 426         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 427         ;;
 428 *) #(vi
 429         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 430         ;;
 431 esac
 432 AC_SUBST(TERMINFO_SRC)
 433
 434 if test "$use_database" != no ; then
 435         AC_DEFINE(USE_DATABASE)
 436
 437         AC_MSG_CHECKING(which terminfo source-file will be installed)
 438         AC_ARG_WITH(database,
 439                 [  --with-database=XXX     specify terminfo source to install],
 440                 [TERMINFO_SRC=$withval])
 441         AC_MSG_RESULT($TERMINFO_SRC)
 442
 443         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 444         AC_ARG_WITH(hashed-db,
 445                 [  --with-hashed-db        specify hashed-database library],,
 446                 [with_hashed_db=no])
 447         AC_MSG_RESULT($with_hashed_db)
 448 else
 449         with_hashed_db=no
 450 fi
 451
 452 AC_MSG_CHECKING(for list of fallback descriptions)
 453 AC_ARG_WITH(fallbacks,
 454         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 455         [with_fallback=$withval],
 456         [with_fallback=])
 457 AC_MSG_RESULT($with_fallback)
 458 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 459 AC_SUBST(FALLBACK_LIST)
 460
 461 AC_MSG_CHECKING(if you want modern xterm or antique)
 462 AC_ARG_WITH(xterm-new,
 463         [  --without-xterm-new     specify if xterm terminfo should be old version],
 464         [with_xterm_new=$withval],
 465         [with_xterm_new=yes])
 466 case $with_xterm_new in
 467 no)     with_xterm_new=xterm-old;;
 468 *)      with_xterm_new=xterm-new;;
 469 esac
 470 AC_MSG_RESULT($with_xterm_new)
 471 WHICH_XTERM=$with_xterm_new
 472 AC_SUBST(WHICH_XTERM)
 473
 474 MAKE_TERMINFO=
 475 if test "$use_database" = no ; then
 476         TERMINFO="${datadir}/terminfo"
 477         MAKE_TERMINFO="#"
 478 else
 479
 480 AC_MSG_CHECKING(for list of terminfo directories)
 481 CF_WITH_PATHLIST(terminfo-dirs,
 482         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 483         TERMINFO_DIRS,
 484         DATADIR/terminfo,
 485         ${datadir}/terminfo)
 486 AC_MSG_RESULT($TERMINFO_DIRS)
 487 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
 488
 489 AC_MSG_CHECKING(for default terminfo directory)
 490 CF_WITH_PATH(default-terminfo-dir,
 491         [  --with-default-terminfo-dir=DIR default terminfo directory],
 492         TERMINFO,
 493         DATADIR/terminfo,
 494         ${datadir}/terminfo)
 495 AC_MSG_RESULT($TERMINFO)
 496 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
 497
 498 fi
 499
 500 AC_SUBST(TERMINFO)
 501 AC_SUBST(MAKE_TERMINFO)
 502
 503 ###     use option --disable-big-core to make tic run on small machines
 504 ###     We need 4Mb, check if we can allocate 50% more than that.
 505 AC_MSG_CHECKING(if big-core option selected)
 506 AC_ARG_ENABLE(big-core,
 507         [  --disable-big-core      assume machine has little memory],
 508         [with_big_core=$enableval],
 509         [AC_TRY_RUN([
 510 #include <stdlib.h>
 511 #include <string.h>
 512 int main() {
 513         unsigned long n = 6000000L;
 514         char *s = malloc(n);
 515         if (s != 0)
 516                 s[0] = s[n-1] = 0;
 517         ${cf_cv_main_return:-return}(s == 0);
 518 }],
 519         [with_big_core=yes],
 520         [with_big_core=no],
 521         [with_big_core=no])])
 522 AC_MSG_RESULT($with_big_core)
 523 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
 524
 525 ### ISO C only guarantees 512-char strings, we have tables which load faster
 526 ### when constructed using "big" strings.  More than the C compiler, the awk
 527 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 528 AC_MSG_CHECKING(if big-strings option selected)
 529 AC_ARG_ENABLE(big-strings,
 530         [  --disable-big-strings   assume compiler has only standard-size strings],
 531         [with_big_strings=$enableval],
 532         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 533 AC_MSG_RESULT($with_big_strings)
 534
 535 USE_BIG_STRINGS=0
 536 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
 537 AC_SUBST(USE_BIG_STRINGS)
 538
 539 ###     use option --enable-termcap to compile in the termcap fallback support
 540 AC_MSG_CHECKING(if you want termcap-fallback support)
 541 AC_ARG_ENABLE(termcap,
 542         [  --enable-termcap        compile in termcap fallback support],
 543         [with_termcap=$enableval],
 544         [with_termcap=no])
 545 AC_MSG_RESULT($with_termcap)
 546
 547 if test "$with_termcap" != "yes" ; then
 548         if test "$use_database" = no ; then
 549                 if test -z "$with_fallback" ; then
 550                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 551                 fi
 552         fi
 553         AC_DEFINE(PURE_TERMINFO)
 554 else
 555
 556 if test "$with_ticlib" != no ; then
 557         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 558 fi
 559
 560 AC_DEFINE(USE_TERMCAP)
 561 AC_MSG_CHECKING(for list of termcap files)
 562 CF_WITH_PATHLIST(termpath,
 563         [  --with-termpath=XXX     specify list of termcap files],
 564         TERMPATH,
 565         /etc/termcap:/usr/share/misc/termcap)
 566 AC_MSG_RESULT($TERMPATH)
 567 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
 568
 569 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 570 AC_MSG_CHECKING(if fast termcap-loader is needed)
 571 AC_ARG_ENABLE(getcap,
 572         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 573         [with_getcap=$enableval],
 574         [with_getcap=no])
 575 AC_MSG_RESULT($with_getcap)
 576 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
 577
 578 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 579 AC_ARG_ENABLE(getcap-cache,
 580         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 581         [with_getcap_cache=$enableval],
 582         [with_getcap_cache=no])
 583 AC_MSG_RESULT($with_getcap_cache)
 584 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
 585
 586 fi
 587
 588 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 589 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 590 AC_ARG_ENABLE(home-terminfo,
 591         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 592         [with_home_terminfo=$enableval],
 593         [with_home_terminfo=yes])
 594 AC_MSG_RESULT($with_home_terminfo)
 595 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
 596
 597 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 598 AC_ARG_ENABLE(root-environ,
 599         [  --disable-root-environ  restrict environment when running as root],
 600         [with_root_environ=$enableval],
 601         [with_root_environ=yes])
 602 AC_MSG_RESULT($with_root_environ)
 603 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
 604
 605 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 606 ###   to reduce storage requirements for the terminfo database.
 607 CF_LINK_FUNCS
 608
 609 with_links=no
 610 with_symlinks=no
 611
 612 # soft links (symbolic links) are useful for some systems where hard links do
 613 # not work, or to make it simpler to copy terminfo trees around.
 614 if test "$ac_cv_func_symlink" = yes ; then
 615     AC_MSG_CHECKING(if tic should use symbolic links)
 616     AC_ARG_ENABLE(symlinks,
 617         [  --enable-symlinks       make tic use symbolic links not hard links],
 618         [with_symlinks=$enableval],
 619         [with_symlinks=no])
 620     AC_MSG_RESULT($with_symlinks)
 621 fi
 622
 623 # If we have hard links and did not choose to use soft links instead, there is
 624 # no reason to make this choice optional - use the hard links.
 625 if test "$with_symlinks" = no ; then
 626     AC_MSG_CHECKING(if tic should use hard links)
 627     if test "$ac_cv_func_link" = yes ; then
 628         with_links=yes
 629     else
 630         with_links=no
 631     fi
 632     AC_MSG_RESULT($with_links)
 633 fi
 634
 635 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
 636 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
 637
 638 ###   use option --enable-broken-linker to force on use of broken-linker support
 639 AC_MSG_CHECKING(if you want broken-linker support code)
 640 AC_ARG_ENABLE(broken_linker,
 641         [  --enable-broken_linker  compile with broken-linker support code],
 642         [with_broken_linker=$enableval],
 643         [with_broken_linker=${BROKEN_LINKER:-no}])
 644 AC_MSG_RESULT($with_broken_linker)
 645
 646 BROKEN_LINKER=0
 647 if test "$with_broken_linker" = yes ; then
 648         AC_DEFINE(BROKEN_LINKER)
 649         BROKEN_LINKER=1
 650 elif test "$DFT_LWR_MODEL" = shared ; then
 651         case $cf_cv_system_name in #(vi
 652         cygwin*)
 653                 AC_DEFINE(BROKEN_LINKER)
 654                 BROKEN_LINKER=1
 655                 CF_VERBOSE(cygwin linker is broken anyway)
 656                 ;;
 657         esac
 658 fi
 659 AC_SUBST(BROKEN_LINKER)
 660
 661 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 662 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 663 AC_ARG_ENABLE(bsdpad,
 664         [  --enable-bsdpad         recognize BSD-style prefix padding],
 665         [with_bsdpad=$enableval],
 666         [with_bsdpad=no])
 667 AC_MSG_RESULT($with_bsdpad)
 668 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
 669
 670 ###   use option --enable-widec to turn on use of wide-character support
 671 NCURSES_CH_T=chtype
 672 NCURSES_LIBUTF8=0
 673
 674 NEED_WCHAR_H=0
 675 NCURSES_MBSTATE_T=0
 676 NCURSES_WCHAR_T=0
 677 NCURSES_WINT_T=0
 678
 679 # Check to define _XOPEN_SOURCE "automatically"
 680 CF_XOPEN_SOURCE(500)
 681
 682 # Work around breakage on OS X
 683 CF_SIGWINCH
 684
 685 # Checks for CODESET support.
 686 AM_LANGINFO_CODESET
 687
 688 # use these variables to work around a defect in gcc's fixincludes.
 689 NCURSES_OK_WCHAR_T=
 690 NCURSES_OK_WINT_T=
 691
 692 AC_MSG_CHECKING(if you want wide-character code)
 693 AC_ARG_ENABLE(widec,
 694         [  --enable-widec          compile with wide-char/UTF-8 code],
 695         [with_widec=$enableval],
 696         [with_widec=no])
 697 AC_MSG_RESULT($with_widec)
 698 if test "$with_widec" = yes ; then
 699         LIB_SUFFIX="w${LIB_SUFFIX}"
 700         AC_DEFINE(USE_WIDEC_SUPPORT)
 701         AC_DEFINE(NCURSES_WIDECHAR)
 702
 703         CF_CHECK_WCHAR_H
 704
 705         # with_overwrite=no
 706         NCURSES_CH_T=cchar_t
 707         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 708         if test "$ac_cv_func_putwc" != yes ; then
 709                 CF_UTF8_LIB
 710                 if test "$cf_cv_utf8_lib" != no ; then
 711                         NCURSES_LIBUTF8=1
 712                 fi
 713         fi
 714         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 715         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 716         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 717
 718         if test "$NCURSES_MBSTATE_T" != 0; then
 719                 AC_DEFINE(NEED_MBSTATE_T_DEF)
 720         fi
 721 fi
 722 AC_SUBST(NCURSES_CH_T)
 723 AC_SUBST(NCURSES_LIBUTF8)
 724
 725 AC_SUBST(NEED_WCHAR_H)
 726 AC_SUBST(NCURSES_MBSTATE_T)
 727 AC_SUBST(NCURSES_WCHAR_T)
 728 AC_SUBST(NCURSES_WINT_T)
 729
 730 AC_SUBST(NCURSES_OK_WCHAR_T)
 731 AC_SUBST(NCURSES_OK_WINT_T)
 732
 733 ###   use option --disable-lp64 to allow long chtype
 734 case $cf_cv_abi_version in
 735 [[345]]*)
 736         default_with_lp64=no
 737         ;;
 738 *)
 739         default_with_lp64=yes
 740         ;;
 741 esac
 742
 743 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 744 AC_ARG_ENABLE(lp64,
 745         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 746         [with_lp64=$enableval],
 747         [with_lp64=$default_with_lp64])
 748 AC_MSG_RESULT($with_lp64)
 749
 750 if test "$with_lp64" = yes ; then
 751         cf_cv_enable_lp64=1
 752 else
 753         cf_cv_enable_lp64=0
 754 fi
 755 AC_SUBST(cf_cv_enable_lp64)
 756
 757 CF_LARGEFILE
 758
 759 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 760 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 761 AC_ARG_ENABLE(tparm-varargs,
 762         [  --disable-tparm-varargs compile tparm() without varargs interface],
 763         [with_tparm_varargs=$enableval],
 764         [with_tparm_varargs=yes])
 765 AC_MSG_RESULT($with_tparm_varargs)
 766 NCURSES_TPARM_VARARGS=0
 767 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
 768 AC_SUBST(NCURSES_TPARM_VARARGS)
 769
 770 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 771 if test "$with_ticlib" != no ; then
 772 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 773 AC_ARG_ENABLE(tic-depends,
 774         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 775         [with_tic_depends=$enableval],
 776         [with_tic_depends=yes])
 777 AC_MSG_RESULT($with_tic_depends)
 778 else
 779         with_tic_depends=no
 780 fi
 781
 782 ###   use option --with-bool to override bool's type
 783 AC_MSG_CHECKING(for type of bool)
 784 AC_ARG_WITH(bool,
 785         [  --with-bool=TYPE        override fallback type of bool variable],
 786         [NCURSES_BOOL="$withval"],
 787         [NCURSES_BOOL=auto])
 788 AC_MSG_RESULT($NCURSES_BOOL)
 789 AC_SUBST(NCURSES_BOOL)
 790
 791 AC_MSG_CHECKING(for alternate terminal capabilities file)
 792 AC_ARG_WITH(caps,
 793         [  --with-caps=alt         compile with alternate Caps file],
 794         [TERMINFO_CAPS=Caps.$withval],
 795         [TERMINFO_CAPS=Caps])
 796 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 797 AC_MSG_RESULT($TERMINFO_CAPS)
 798 AC_SUBST(TERMINFO_CAPS)
 799
 800 ###   use option --with-chtype to override chtype's type
 801 AC_MSG_CHECKING(for type of chtype)
 802 AC_ARG_WITH(chtype,
 803         [  --with-chtype=TYPE      override type of chtype],
 804         [NCURSES_CHTYPE="$withval"],
 805         [NCURSES_CHTYPE=auto])
 806 AC_MSG_RESULT($NCURSES_CHTYPE)
 807
 808 ###   use option --with-ospeed to override ospeed's type
 809 AC_MSG_CHECKING(for type of ospeed)
 810 AC_ARG_WITH(ospeed,
 811         [  --with-ospeed=TYPE      override type of ospeed variable],
 812         [NCURSES_OSPEED="$withval"],
 813         [NCURSES_OSPEED=short])
 814 AC_MSG_RESULT($NCURSES_OSPEED)
 815 AC_SUBST(NCURSES_OSPEED)
 816
 817 ###   use option --with-mmask-t to override mmask_t's type
 818 AC_MSG_CHECKING(for type of mmask_t)
 819 AC_ARG_WITH(mmask-t,
 820         [  --with-mmask-t=TYPE     override type of mmask_t],
 821         [NCURSES_MMASK_T="$withval"],
 822         [NCURSES_MMASK_T=auto])
 823 AC_MSG_RESULT($NCURSES_MMASK_T)
 824
 825 ###   use option --with-ccharw-max to override CCHARW_MAX size
 826 AC_MSG_CHECKING(for size CCHARW_MAX)
 827 AC_ARG_WITH(ccharw-max,
 828         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
 829         [NCURSES_CCHARW_MAX="$withval"],
 830         [NCURSES_CCHARW_MAX=5])
 831 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
 832 AC_SUBST(NCURSES_CCHARW_MAX)
 833
 834 ### Enable compiling-in rcs id's
 835 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
 836 AC_ARG_WITH(rcs-ids,
 837         [  --with-rcs-ids          compile-in RCS identifiers],
 838         [with_rcs_ids=$withval],
 839         [with_rcs_ids=no])
 840 AC_MSG_RESULT($with_rcs_ids)
 841 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
 842
 843 ###############################################################################
 844 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
 845
 846 ###############################################################################
 847 CF_HELP_MESSAGE(Extensions:)
 848
 849 ### Note that some functions (such as const) are normally disabled anyway.
 850 AC_MSG_CHECKING(if you want to build with function extensions)
 851 AC_ARG_ENABLE(ext-funcs,
 852         [  --disable-ext-funcs     disable function-extensions],
 853         [with_ext_funcs=$enableval],
 854         [with_ext_funcs=yes])
 855 AC_MSG_RESULT($with_ext_funcs)
 856 if test "$with_ext_funcs" = yes ; then
 857         NCURSES_EXT_FUNCS=1
 858         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS)
 859         AC_DEFINE(HAVE_CURSES_VERSION)
 860         AC_DEFINE(HAVE_HAS_KEY)
 861         AC_DEFINE(HAVE_RESIZETERM)
 862         AC_DEFINE(HAVE_RESIZE_TERM)
 863         AC_DEFINE(HAVE_TERM_ENTRY_H)
 864         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
 865         AC_DEFINE(HAVE_USE_SCREEN)
 866         AC_DEFINE(HAVE_USE_WINDOW)
 867         AC_DEFINE(HAVE_WRESIZE)
 868         AC_DEFINE(NCURSES_EXT_FUNCS)
 869         GENERATED_EXT_FUNCS=generated
 870 else
 871         NCURSES_EXT_FUNCS=0
 872         GENERATED_EXT_FUNCS=
 873 fi
 874 AC_SUBST(NCURSES_EXT_FUNCS)
 875 AC_SUBST(GENERATED_EXT_FUNCS)
 876
 877 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
 878 AC_ARG_ENABLE(sp-funcs,
 879         [  --enable-sp-funcs       enable experimental SCREEN-extensions],
 880         [with_sp_funcs=$enableval],
 881         [with_sp_funcs=no])
 882 AC_MSG_RESULT($with_sp_funcs)
 883 if test "$with_sp_funcs" = yes ; then
 884         NCURSES_SP_FUNCS=1
 885         AC_DEFINE(NCURSES_SP_FUNCS)
 886         GENERATED_SP_FUNCS=generated
 887 else
 888         NCURSES_SP_FUNCS=0
 889         GENERATED_SP_FUNCS=
 890 fi
 891 AC_SUBST(NCURSES_SP_FUNCS)
 892 AC_SUBST(GENERATED_SP_FUNCS)
 893
 894 AC_MSG_CHECKING(if you want to build with experimental terminal-driver)
 895 AC_ARG_ENABLE(term-driver,
 896         [  --enable-term-driver    enable experimental terminal-driver],
 897         [with_term_driver=$enableval],
 898         [with_term_driver=no])
 899 AC_MSG_RESULT($with_term_driver)
 900 if test "$with_term_driver" = yes ; then
 901         AC_DEFINE(USE_TERM_DRIVER)
 902         if test "$with_sp_funcs" != yes ; then
 903                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
 904         fi
 905 fi
 906
 907 ###   use option --enable-const to turn on use of const beyond that in XSI.
 908 AC_MSG_CHECKING(for extended use of const keyword)
 909 AC_ARG_ENABLE(const,
 910         [  --enable-const          compile with extra/non-standard const],
 911         [with_ext_const=$enableval],
 912         [with_ext_const=no])
 913 AC_MSG_RESULT($with_ext_const)
 914 NCURSES_CONST='/*nothing*/'
 915 if test "$with_ext_const" = yes ; then
 916         NCURSES_CONST=const
 917 fi
 918 AC_SUBST(NCURSES_CONST)
 919
 920 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
 921 AC_MSG_CHECKING(if you want to use extended colors)
 922 AC_ARG_ENABLE(ext-colors,
 923         [  --enable-ext-colors     compile for 256-color support],
 924         [with_ext_colors=$enableval],
 925         [with_ext_colors=no])
 926 AC_MSG_RESULT($with_ext_colors)
 927 NCURSES_EXT_COLORS=0
 928 if test "$with_ext_colors" = yes ; then
 929         if test "$with_widec" != yes ; then
 930                 AC_MSG_ERROR(This option applies only to wide-character library)
 931         else
 932                 # cannot be ABI 5 since it changes sizeof(cchar_t)
 933                 CF_NCURSES_ABI_6
 934         fi
 935         NCURSES_EXT_COLORS=1
 936         AC_DEFINE(NCURSES_EXT_COLORS)
 937 fi
 938 AC_SUBST(NCURSES_EXT_COLORS)
 939
 940 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
 941 AC_MSG_CHECKING(if you want to use extended mouse encoding)
 942 AC_ARG_ENABLE(ext-mouse,
 943         [  --enable-ext-mouse      compile for extended mouse-encoding],
 944         [with_ext_mouse=$enableval],
 945         [with_ext_mouse=no])
 946 AC_MSG_RESULT($with_ext_mouse)
 947 NCURSES_MOUSE_VERSION=1
 948 if test "$with_ext_mouse" = yes ; then
 949         NCURSES_MOUSE_VERSION=2
 950         CF_NCURSES_ABI_6
 951 fi
 952 AC_SUBST(NCURSES_MOUSE_VERSION)
 953
 954 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
 955 AC_ARG_ENABLE(no-padding,
 956         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
 957         [with_no_padding=$enableval],
 958         [with_no_padding=$with_ext_funcs])
 959 AC_MSG_RESULT($with_no_padding)
 960 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
 961
 962 AC_CHECK_SIZEOF([signed char], 0)
 963 if test "$ac_cv_sizeof_signed_char" = 1 ; then
 964         NCURSES_SBOOL="signed char"
 965 else
 966         NCURSES_SBOOL="char"
 967 fi
 968 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
 969 AC_ARG_ENABLE(signed-char,
 970         [  --enable-signed-char    compile using signed Boolean's in term.h],
 971         [with_signed_char=$enableval],
 972         [with_signed_char=no])
 973 AC_MSG_RESULT($with_signed_char)
 974 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
 975 AC_SUBST(NCURSES_SBOOL)
 976
 977 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
 978 AC_MSG_CHECKING(if you want SIGWINCH handler)
 979 AC_ARG_ENABLE(sigwinch,
 980         [  --enable-sigwinch       compile with SIGWINCH handler],
 981         [with_sigwinch=$enableval],
 982         [with_sigwinch=$with_ext_funcs])
 983 AC_MSG_RESULT($with_sigwinch)
 984 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
 985
 986 ###   use option --enable-tcap-names to allow user to define new capabilities
 987 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
 988 AC_ARG_ENABLE(tcap-names,
 989         [  --enable-tcap-names     compile with user-definable terminal capabilities],
 990         [with_tcap_names=$enableval],
 991         [with_tcap_names=$with_ext_funcs])
 992 AC_MSG_RESULT($with_tcap_names)
 993 NCURSES_XNAMES=0
 994 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
 995 AC_SUBST(NCURSES_XNAMES)
 996
 997 ###############################################################################
 998 # These options are relatively safe to experiment with.
 999 CF_HELP_MESSAGE(Development Code:)
1000 AC_MSG_CHECKING(if you want all development code)
1001 AC_ARG_WITH(develop,
1002         [  --without-develop       disable development options],
1003         [with_develop=$withval],
1004         [with_develop=no])
1005 AC_MSG_RESULT($with_develop)
1006
1007 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1008 AC_MSG_CHECKING(if you want hard-tabs code)
1009 AC_ARG_ENABLE(hard-tabs,
1010         [  --enable-hard-tabs      compile with hard-tabs code],,
1011         [enable_hard_tabs=$with_develop])
1012 AC_MSG_RESULT($enable_hard_tabs)
1013 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
1014
1015 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1016 AC_MSG_CHECKING(if you want limited support for xmc)
1017 AC_ARG_ENABLE(xmc-glitch,
1018         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1019         [enable_xmc_glitch=$with_develop])
1020 AC_MSG_RESULT($enable_xmc_glitch)
1021 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
1022
1023 ###############################################################################
1024 # These are just experimental, probably should not be in a package:
1025 CF_HELP_MESSAGE(Experimental Code:)
1026
1027 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1028 AC_ARG_ENABLE(assumed-color,
1029         [  --disable-assumed-color do not assume anything about default-colors],
1030         [with_assumed_color=$enableval],
1031         [with_assumed_color=yes])
1032 AC_MSG_RESULT($with_assumed_color)
1033 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
1034
1035 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1036 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1037 AC_ARG_ENABLE(hashmap,
1038         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1039         [with_hashmap=$enableval],
1040         [with_hashmap=yes])
1041 AC_MSG_RESULT($with_hashmap)
1042 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
1043
1044 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1045 AC_MSG_CHECKING(if you want colorfgbg code)
1046 AC_ARG_ENABLE(colorfgbg,
1047         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1048         [with_colorfgbg=$enableval],
1049         [with_colorfgbg=no])
1050 AC_MSG_RESULT($with_colorfgbg)
1051 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
1052
1053 ###   use option --enable-interop to turn on use of bindings used for interop
1054 AC_MSG_CHECKING(if you want interop bindings)
1055 AC_ARG_ENABLE(interop,
1056         [  --enable-interop        compile-in experimental interop bindings],
1057         [with_exp_interop=$enableval],
1058         [with_exp_interop=no])
1059 AC_MSG_RESULT($with_exp_interop)
1060
1061 NCURSES_INTEROP_FUNCS=0
1062 test "$with_exp_interop" = yes && NCURSES_INTEROP_FUNCS=1
1063 AC_SUBST(NCURSES_INTEROP_FUNCS)
1064
1065 # This is still experimental (20080329), but should ultimately be moved to
1066 # the script-block --with-normal, etc.
1067 CF_WITH_PTHREAD
1068
1069 if test "x$with_pthread" != xno; then
1070         AC_CHECK_FUNC(pthread_kill,[
1071                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1072                 AC_ARG_ENABLE(pthreads-eintr,
1073                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1074                         [use_pthreads_eintr=$enableval],
1075                         [use_pthreads_eintr=no])
1076                 AC_MSG_RESULT($use_pthreads_eintr)
1077                 if test $use_pthreads_eintr = yes ; then
1078                         AC_DEFINE(USE_PTHREADS_EINTR)
1079                 fi])
1080
1081         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1082         AC_ARG_ENABLE(weak-symbols,
1083                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1084                 [use_weak_symbols=$enableval],
1085                 [use_weak_symbols=no])
1086         AC_MSG_RESULT($use_weak_symbols)
1087         if test "$use_weak_symbols" = yes ; then
1088                 CF_WEAK_SYMBOLS
1089         else
1090                 cf_cv_weak_symbols=no
1091         fi
1092
1093         if test $cf_cv_weak_symbols = yes ; then
1094                 AC_DEFINE(USE_WEAK_SYMBOLS)
1095         fi
1096 fi
1097
1098 PTHREAD=
1099 if test "$with_pthread" = "yes" ; then
1100     AC_DEFINE(USE_PTHREADS)
1101     enable_reentrant=yes
1102     if test $cf_cv_weak_symbols = yes ; then
1103         PTHREAD=-lpthread
1104     fi
1105 fi
1106 AC_SUBST(PTHREAD)
1107
1108 # Reentrant code has to be opaque; there's little advantage to making ncurses
1109 # opaque outside of that, so there is no --enable-opaque option.  We can use
1110 # this option without --with-pthreads, but this will be always set for
1111 # pthreads.
1112 AC_MSG_CHECKING(if you want experimental reentrant code)
1113 AC_ARG_ENABLE(reentrant,
1114         [  --enable-reentrant      compile with experimental reentrant code],
1115         [with_reentrant=$enableval],
1116         [with_reentrant=no])
1117 AC_MSG_RESULT($with_reentrant)
1118 if test "$with_reentrant" = yes ; then
1119         cf_cv_enable_reentrant=1
1120         cf_cv_enable_opaque="NCURSES_INTERNALS"
1121         NCURSES_OPAQUE=1
1122         NCURSES_SIZE_T=int
1123         if test $cf_cv_weak_symbols = yes ; then
1124                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1125                 CF_ADD_LIB(pthread,TEST_LIBS)
1126                 CF_ADD_LIB(pthread,TEST_LIBS2)
1127         else
1128                 LIB_SUFFIX="t${LIB_SUFFIX}"
1129         fi
1130         AC_DEFINE(USE_REENTRANT)
1131         CF_NCURSES_ABI_6
1132 else
1133         cf_cv_enable_reentrant=0
1134         cf_cv_enable_opaque="NCURSES_OPAQUE"
1135         NCURSES_OPAQUE=0
1136         NCURSES_SIZE_T=short
1137 fi
1138 AC_SUBST(cf_cv_enable_reentrant)
1139 AC_SUBST(cf_cv_enable_opaque)
1140 AC_SUBST(NCURSES_OPAQUE)
1141 AC_SUBST(NCURSES_SIZE_T)
1142
1143 ### Allow using a different wrap-prefix
1144 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1145         AC_MSG_CHECKING(for prefix used to wrap public variables)
1146         AC_ARG_WITH(wrap-prefix,
1147                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1148                 [NCURSES_WRAP_PREFIX=$withval],
1149                 [NCURSES_WRAP_PREFIX=_nc_])
1150         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1151 else
1152         NCURSES_WRAP_PREFIX=_nc_
1153 fi
1154 AC_SUBST(NCURSES_WRAP_PREFIX)
1155 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX")
1156
1157 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1158 AC_ARG_ENABLE(safe-sprintf,
1159         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1160         [with_safe_sprintf=$enableval],
1161         [with_safe_sprintf=no])
1162 AC_MSG_RESULT($with_safe_sprintf)
1163 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1164
1165 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1166 # when hashmap is used scroll hints are useless
1167 if test "$with_hashmap" = no ; then
1168 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1169 AC_ARG_ENABLE(scroll-hints,
1170         [  --disable-scroll-hints  compile without scroll-hints code],
1171         [with_scroll_hints=$enableval],
1172         [with_scroll_hints=yes])
1173 AC_MSG_RESULT($with_scroll_hints)
1174 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1175 fi
1176
1177 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1178 AC_ARG_ENABLE(wgetch-events,
1179         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1180         [with_wgetch_events=$enableval],
1181         [with_wgetch_events=no])
1182 AC_MSG_RESULT($with_wgetch_events)
1183 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1184
1185 ###############################################################################
1186 CF_HELP_MESSAGE(Testing/development Options:)
1187
1188 ###     use option --disable-echo to suppress full display compiling commands
1189 AC_MSG_CHECKING(if you want to display full commands during build)
1190 AC_ARG_ENABLE(echo,
1191         [  --enable-echo           build: display "compiling" commands (default)],
1192         [with_echo=$enableval],
1193         [with_echo=yes])
1194 if test "$with_echo" = yes; then
1195         ECHO_LINK=
1196 else
1197         ECHO_LINK='@ echo linking $@ ... ;'
1198         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1199         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1200 fi
1201 AC_MSG_RESULT($with_echo)
1202 AC_SUBST(ECHO_LINK)
1203
1204 ###     use option --enable-warnings to turn on all gcc warnings
1205 AC_MSG_CHECKING(if you want to see compiler warnings)
1206 AC_ARG_ENABLE(warnings,
1207         [  --enable-warnings       build: turn on GCC compiler warnings],
1208         [with_warnings=$enableval])
1209 AC_MSG_RESULT($with_warnings)
1210
1211 if test "x$with_warnings" = "xyes"; then
1212         CF_ADD_ADAFLAGS(-gnatg)
1213         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1214         if test "$cf_with_cxx" = yes ; then
1215                 CF_GXX_WARNINGS(Wno-unused)
1216         fi
1217 fi
1218 CF_GCC_ATTRIBUTES
1219
1220 ###     use option --enable-assertions to turn on generation of assertion code
1221 AC_MSG_CHECKING(if you want to enable runtime assertions)
1222 AC_ARG_ENABLE(assertions,
1223         [  --enable-assertions     test: turn on generation of assertion code],
1224         [with_assertions=$enableval],
1225         [with_assertions=no])
1226 AC_MSG_RESULT($with_assertions)
1227 if test -n "$GCC"
1228 then
1229         if test "$with_assertions" = no
1230         then
1231                 AC_DEFINE(NDEBUG)
1232                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1233         else
1234                 CF_ADD_ADAFLAGS(-gnata)
1235         fi
1236 fi
1237
1238 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1239 CF_DISABLE_LEAKS
1240 AC_DEFINE(HAVE_NC_ALLOC_H)
1241
1242 ###     use option --enable-expanded to generate certain macros as functions
1243 AC_ARG_ENABLE(expanded,
1244         [  --enable-expanded       test: generate functions for certain macros],
1245         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1246
1247 ###     use option --disable-macros to suppress macros in favor of functions
1248 AC_ARG_ENABLE(macros,
1249         [  --disable-macros        test: use functions rather than macros],
1250         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1251
1252 # Normally we only add trace() to the debug-library.  Allow this to be
1253 # extended to all models of the ncurses library:
1254 cf_all_traces=no
1255 case "$CFLAGS $CPPFLAGS" in
1256 *-DTRACE*)
1257         cf_all_traces=yes
1258         ;;
1259 esac
1260
1261 AC_MSG_CHECKING(whether to add trace feature to all models)
1262 AC_ARG_WITH(trace,
1263 [  --with-trace            test: add trace() function to all models of ncurses],
1264 [cf_with_trace=$withval],
1265 [cf_with_trace=$cf_all_traces])
1266 AC_MSG_RESULT($cf_with_trace)
1267
1268 if test "$cf_with_trace" = yes ; then
1269         LIB_TRACING=all
1270         ADA_TRACE=TRUE
1271         CF_ADD_CFLAGS(-DTRACE)
1272 else
1273         LIB_TRACING=DEBUG
1274         ADA_TRACE=FALSE
1275 fi
1276
1277 AC_SUBST(ADA_TRACE)
1278
1279 ###     Checks for libraries.
1280 case $cf_cv_system_name in #(vi
1281 *mingw32*) #(vi
1282         ;;
1283 *)
1284 AC_CHECK_FUNC(gettimeofday,
1285         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1286
1287 AC_CHECK_LIB(bsd, gettimeofday,
1288         AC_DEFINE(HAVE_GETTIMEOFDAY)
1289         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1290         ;;
1291 esac
1292
1293 CF_MATH_LIB(MATH_LIB,sin(x))
1294 AC_SUBST(MATH_LIB)
1295
1296 ###     Checks for header files.
1297 AC_STDC_HEADERS
1298 AC_HEADER_DIRENT
1299 AC_HEADER_TIME
1300 CF_REGEX
1301
1302 dnl These are some other potentially nonportable headers.
1303 AC_CHECK_HEADERS( \
1304 fcntl.h \
1305 getopt.h \
1306 limits.h \
1307 locale.h \
1308 math.h \
1309 poll.h \
1310 sys/bsdtypes.h \
1311 sys/ioctl.h \
1312 sys/param.h \
1313 sys/poll.h \
1314 sys/select.h \
1315 sys/time.h \
1316 sys/times.h \
1317 ttyent.h \
1318 unistd.h \
1319 wctype.h \
1320 )
1321
1322 CF_GETOPT_HEADER
1323
1324 # check for ISC (this may also define _POSIX_SOURCE)
1325 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1326 if test "$ISC" = yes ; then
1327         AC_CHECK_LIB(cposix,main)
1328         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1329 fi
1330
1331 CF_SYS_TIME_SELECT
1332
1333 ###     checks for compiler characteristics
1334 AC_LANG_C
1335 AC_C_CONST
1336 CF_C_INLINE(NCURSES_INLINE,1200)
1337 CF_SIG_ATOMIC_T
1338
1339 if test $NCURSES_CHTYPE = auto ; then
1340         CF_TYPEOF_CHTYPE
1341 else
1342         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1343 fi
1344 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1345 AC_SUBST(cf_cv_typeof_chtype)
1346
1347 CF_UNSIGNED_LITERALS
1348 cf_cv_1UL="1"
1349 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1350 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1351 AC_SUBST(cf_cv_1UL)
1352
1353 if test $NCURSES_MMASK_T = auto ; then
1354         cf_cv_typeof_mmask_t=long
1355 else
1356         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1357 fi
1358 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1359 AC_SUBST(cf_cv_typeof_mmask_t)
1360
1361 ###     Checks for external-data
1362 CF_ERRNO
1363 CF_LINK_DATAONLY
1364
1365 ###     Checks for library functions.
1366 AC_CHECK_FUNCS( \
1367 getcwd \
1368 getegid \
1369 geteuid \
1370 getttynam \
1371 issetugid \
1372 poll \
1373 remove \
1374 select \
1375 setbuf \
1376 setbuffer \
1377 setvbuf \
1378 sigaction \
1379 sigvec \
1380 strdup \
1381 strstr \
1382 tcgetpgrp \
1383 times \
1384 vsnprintf \
1385 )
1386 if test "$with_getcap" = "yes" ; then
1387         CF_CGETENT
1388 fi
1389
1390 CF_ISASCII
1391 CF_STRUCT_SIGACTION
1392 CF_FUNC_NANOSLEEP
1393 CF_FUNC_TERMIOS
1394 CF_FUNC_VSSCANF
1395 CF_MKSTEMP
1396
1397 # setup for prototype of fallback for vsscanf()
1398 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1399
1400 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1401 if test "$cross_compiling" = yes ; then
1402         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1403 else
1404         AC_FUNC_SETVBUF_REVERSED
1405 fi
1406 AC_TYPE_SIGNAL
1407 AC_CHECK_TYPE(intptr_t, long)
1408 CF_TYPE_SIGACTION
1409 CF_SIZECHANGE
1410 CF_FUNC_MEMMOVE
1411 CF_FUNC_POLL
1412 CF_VA_COPY
1413 AC_FUNC_VFORK
1414
1415 # special check for test/ditto.c
1416 CF_FUNC_OPENPTY
1417 if test "$cf_cv_func_openpty" != no ; then
1418     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1419     AC_DEFINE(USE_XTERM_PTY)
1420     if test "$cf_cv_lib_util" = yes ; then
1421         CF_ADD_LIB(util,TEST_LIBS)
1422     fi
1423 fi
1424 AC_SUBST(TEST_LIBS)
1425 AC_SUBST(TEST_LIBS2)
1426
1427 if test "$with_hashed_db" != no ; then
1428         AC_DEFINE(USE_HASHED_DB)
1429         CF_HASHED_DB($with_hashed_db)
1430 fi
1431
1432 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1433 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1434         CF_STRIP_G_OPT(CFLAGS)
1435         CF_STRIP_G_OPT(CXXFLAGS)
1436 fi
1437
1438 # Just in case, check if the C compiler has a bool type.
1439 CF_BOOL_DECL(cf_cv_cc_bool_type)
1440
1441 # Check for C++ compiler characteristics (and ensure that it's there!)
1442 if test -n "$CXX" ; then
1443         AC_LANG_CPLUSPLUS
1444         CF_STDCPP_LIBRARY
1445         CF_PROG_CC_C_O(CXX)
1446
1447         case $GXX_VERSION in
1448         1*|2.[0-6]*)
1449                 cf_cxx_library=yes
1450                 ;;
1451         *-2.7*|2.7*)
1452                 CF_GPP_LIBRARY
1453                 ;;
1454         *)
1455                 cf_cxx_library=no
1456                 ;;
1457         esac
1458
1459         AC_CHECK_HEADERS(typeinfo)
1460         CF_CXX_IOSTREAM_NAMESPACE
1461         CF_BOOL_DECL
1462         CF_BOOL_SIZE
1463         CF_ETIP_DEFINES
1464         CF_CPP_PARAM_INIT
1465         CF_CPP_STATIC_CAST
1466         CF_CXX_AR_FLAGS
1467 else
1468         cf_cxx_library=no
1469         cf_cv_builtin_bool=1
1470
1471         # Just because we are not configuring against C++ right now does not
1472         # mean that a user will not want to use C++.  Some distributors disable
1473         # the C++ portion of this configuration as a shortcut (or just to avoid
1474         # compiling the demo in the c++ directory).  So we need a reasonable
1475         # default for the 'bool' type.
1476         #
1477         # Caveat: since the storage of the bool type is not standardized, it
1478         # may change.
1479
1480         if test "$NCURSES_BOOL" != auto ; then
1481                 cf_cv_type_of_bool=$NCURSES_BOOL
1482                 cf_cv_header_stdbool_h=0
1483         else
1484                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1485                         CF_BOOL_SIZE
1486                 else
1487                         AC_MSG_CHECKING(for fallback type of bool)
1488                         case "$host_cpu" in #(vi
1489                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1490                         *)      cf_cv_type_of_bool=int  ;;
1491                         esac
1492                         AC_MSG_RESULT($cf_cv_type_of_bool)
1493                 fi
1494         fi
1495 fi
1496 AC_SUBST(CXXLIBS)
1497
1498 # If the C compiler did not declare bool, and we did not determine that the C++
1499 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1500 # ncurses library use the same type as C++ bool.  Note that this allows one to
1501 # specify the type of bool in a configure-script option and postpone
1502 # integration with the C++ compiler provided that the types are compatible.
1503 USE_CXX_BOOL=1
1504 if test $cf_cv_cc_bool_type = 1
1505 then
1506         # oops: C has a bool.  Unlikely, but C++ could differ.
1507         USE_CXX_BOOL=0
1508 elif test $cf_cv_builtin_bool = 0
1509 then
1510         # C++ has no bool
1511         USE_CXX_BOOL=0
1512 else
1513         # this is the normal case
1514         USE_CXX_BOOL='defined(__cplusplus)'
1515 fi
1516 AC_SUBST(USE_CXX_BOOL)
1517
1518 CF_HELP_MESSAGE(Ada95 Binding Options:)
1519
1520 dnl If the Ada95 source-tree is present, add that to the build unless it will
1521 dnl not work, or was not requested.
1522 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1523
1524 dnl libtool does not know anything about GNAT, though a change made in 1998
1525 dnl provided for it "someday".  Disable the ada subtree if we are using
1526 dnl libtool -TD 20070714
1527         if test "$cf_with_ada" != "no" ; then
1528                 if test "$with_libtool" != "no"; then
1529                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1530                         cf_with_ada=no
1531                 fi
1532         fi
1533
1534 dnl Check for availability of GNU Ada Translator (GNAT).
1535 dnl At the moment we support no other Ada95 compiler.
1536         if test "$cf_with_ada" != "no" ; then
1537                 CF_PROG_GNAT
1538                 if test "$cf_cv_prog_gnat_correct" = yes; then
1539                         CF_ADD_ADAFLAGS(-gnatpn)
1540
1541                         # make ADAFLAGS consistent with CFLAGS
1542                         case "$CFLAGS" in
1543                         *-g*)
1544                                 CF_ADD_ADAFLAGS(-g)
1545                                 ;;
1546                         esac
1547                         case "$CFLAGS" in
1548                         *-O*)
1549                                 CF_ADD_ADAFLAGS(-O3)
1550                                 ;;
1551                         esac
1552
1553                         CF_GNAT_GENERICS
1554                         CF_GNAT_SIGINT
1555                         CF_GNAT_PRAGMA_UNREF
1556                         CF_GNAT_PROJECTS
1557
1558                         CF_WITH_ADA_COMPILER
1559
1560                         cf_ada_package=terminal_interface
1561                         AC_SUBST(cf_ada_package)
1562
1563                         CF_WITH_ADA_INCLUDE
1564                         CF_WITH_ADA_OBJECTS
1565                         CF_WITH_ADA_SHAREDLIB
1566                 fi
1567         fi
1568 else
1569         cf_with_ada=no
1570 fi
1571
1572 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1573 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1574 ###
1575 ### ticlib modules may be a separate library, otherwise contained in termlib.
1576 ### termlib modules may be a separate library, otherwise contained in ncurses.
1577 ###
1578 ### The of "+" or " " between the tokens controls the way the script
1579 ### chooses to split module lists into libraries.
1580 ###
1581 ### (see CF_LIB_RULES).
1582 AC_MSG_CHECKING(for library subsets)
1583 LIB_SUBSETS=
1584
1585 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1586         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1587         if test "$with_ticlib" != no ; then
1588                 LIB_SUBSETS="${LIB_SUBSETS} "
1589         else
1590                 LIB_SUBSETS="${LIB_SUBSETS}+"
1591         fi
1592 fi
1593
1594 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1595 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1596
1597 if test "$with_termlib" != no ; then
1598         LIB_SUBSETS="${LIB_SUBSETS} "
1599 else
1600         LIB_SUBSETS="${LIB_SUBSETS}+"
1601 fi
1602
1603 LIB_SUBSETS="${LIB_SUBSETS}base"
1604
1605 # Most term-driver calls are to tinfo, but some like init_pair are to the
1606 # base library (so it resides in base).
1607 if test "$with_term_driver" != no ; then
1608         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1609         case $cf_cv_system_name in #(vi
1610         *mingw32*) #(vi
1611                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1612                 ;;
1613         *) #(vi
1614                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1615                 ;;
1616         esac
1617 fi
1618
1619 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1620 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1621
1622 AC_MSG_RESULT($LIB_SUBSETS)
1623
1624 ### Construct the list of include-directories to be generated
1625 CF_INCLUDE_DIRS
1626 CF_ADA_INCLUDE_DIRS
1627
1628 ### Build up pieces for makefile rules
1629 AC_MSG_CHECKING(default library suffix)
1630 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1631 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1632 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1633
1634 AC_MSG_CHECKING(default library-dependency suffix)
1635 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1636 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1637 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1638
1639 AC_MSG_CHECKING(default object directory)
1640 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1641 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1642 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1643
1644 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1645 if test "$cf_with_cxx" = yes ; then
1646 AC_MSG_CHECKING(c++ library-dependency suffix)
1647 if test "$with_libtool" != "no"; then
1648         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1649 else
1650         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)dnl we normally make a static library
1651 fi
1652 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1653 AC_SUBST(CXX_LIB_SUFFIX)
1654 fi
1655
1656 # do not want -ldl in build except as needed for -lncurses dependency
1657 if test "$with_dlsym" = yes ; then
1658 if test $DFT_LWR_MODEL = shared || \
1659    test $DFT_LWR_MODEL = libtool ; then
1660         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1661 fi
1662 fi
1663 ### Set up low-level terminfo dependencies for makefiles.
1664
1665 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1666 # do not need libdl
1667 TICS_LIST=
1668 if test "$with_dlsym" = yes ; then
1669         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1670 fi
1671
1672 if test "$with_ticlib" != no ; then
1673
1674         if test "$with_ticlib" != yes ; then
1675                 TICS_NAME=$with_ticlib
1676                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1677                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1678                 TICS_LIB_SUFFIX="${with_ticlib}"
1679         else
1680                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1681                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1682                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1683         fi
1684         TICS_LDFLAGS="-L${LIB_DIR}"
1685         TICS_LIBS="-l${TICS_LIB_SUFFIX}"
1686 else
1687         TICS_LDFLAGS="-L${LIB_DIR}"
1688         TICS_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX}"
1689 fi
1690 AC_SUBST(TICS_ARG_SUFFIX)
1691 AC_SUBST(TICS_DEP_SUFFIX)
1692 AC_SUBST(TICS_LIB_SUFFIX)
1693 AC_SUBST(TICS_LDFLAGS)
1694 AC_SUBST(TICS_LIBS)
1695
1696 if test "$with_termlib" != no ; then
1697
1698         if test "$with_termlib" != yes ; then
1699                 TINFO_NAME=$with_termlib
1700                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1701                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1702                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1703                 TINFO_LIB_SUFFIX="${with_termlib}"
1704         else
1705                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1706                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1707                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1708                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1709         fi
1710
1711         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1712         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1713         if test "$DFT_LWR_MODEL" = "libtool"; then
1714                 TEST_ARGS="${TEST_DEPS}"
1715                 TEST_ARG2="${TEST_DEP2}"
1716                 TINFO_LDFLAGS="-L${LIB_DIR}"
1717                 TINFO_LIBS="$TEST_ARGS"
1718                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1719                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1720         else
1721                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1722                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1723                 if test "x$with_term_driver" != xno ; then
1724                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1725                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1726                         TINFO_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
1727                 else
1728                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1729                         TINFO_LIBS="$TEST_ARGS"
1730                 fi
1731                 TINFO_LDFLAGS="-L${LIB_DIR}"
1732                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1733         fi
1734 else
1735         # the next lines are needed for linking libtic over libncurses
1736         TINFO_NAME=${LIB_NAME}
1737         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1738         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1739         if test "$with_tic_depends" = yes ; then
1740                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1741         else
1742                 TICS_LIST="$SHLIB_LIST"
1743         fi
1744
1745         TINFO_LDFLAGS="-L${LIB_DIR}"
1746         TINFO_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX}"
1747 fi
1748
1749 if test "$DFT_LWR_MODEL" = shared ; then
1750         case $cf_cv_system_name in #(vi
1751         cygwin*)
1752                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1753                 TINFO_SUFFIX=.dll
1754                 ;;
1755         esac
1756 fi
1757
1758 AC_SUBST(TINFO_ARG_SUFFIX)
1759 AC_SUBST(TINFO_DEP_SUFFIX)
1760 AC_SUBST(TINFO_LIB_SUFFIX)
1761 AC_SUBST(TINFO_LDFLAGS)
1762 AC_SUBST(TINFO_LIBS)
1763
1764 if test "$with_dlsym" = yes ; then
1765         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1766 fi
1767
1768 if test "$DFT_LWR_MODEL" = "libtool"; then
1769     OBJEXT=lo
1770 fi
1771
1772 # needed for Ada95
1773 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
1774 AC_SUBST(TINFO_LDFLAGS2)
1775
1776 case $DFT_LWR_MODEL in
1777 normal|debug|profile)
1778         CF_LDFLAGS_STATIC
1779         ;;
1780 esac
1781
1782 AC_MSG_CHECKING(where we will install curses.h)
1783 test "$with_overwrite" = no && \
1784 test "x$includedir" = 'x${prefix}/include' && \
1785         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1786 AC_MSG_RESULT($includedir)
1787
1788 ### Resolve a conflict between normal and wide-curses by forcing applications
1789 ### that will need libutf8 to add it to their configure script.
1790 if test "$with_overwrite" != no ; then
1791 if test "$NCURSES_LIBUTF8" = 1 ; then
1792         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1793         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1794 fi
1795 fi
1796 WITH_OVERWRITE=$with_overwrite
1797
1798 AC_SUBST(WITH_OVERWRITE)
1799 AC_SUBST(TICS_LIST)
1800 AC_SUBST(TINFO_LIST)
1801 AC_SUBST(SHLIB_LIST)
1802
1803 # used to separate tack out of the tree
1804 NCURSES_TREE=
1805 AC_SUBST(NCURSES_TREE)
1806
1807 ### predefined stuff for the test programs
1808 AC_DEFINE(HAVE_SLK_COLOR)
1809
1810 ### Construct the list of subdirectories for which we'll customize makefiles
1811 ### with the appropriate compile-rules.
1812
1813 CF_SRC_MODULES($modules_to_build)
1814
1815 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
1816    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1817    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${DFT_ARG_SUFFIX}-config.1:man/MKada_config.in"
1818 fi
1819
1820 CF_DIRS_TO_MAKE
1821
1822 # symbols that differ when compiling Ada95 by itself.
1823 NCURSES_SHLIB2='sh $(top_srcdir)/misc/shlib'
1824 AC_SUBST(NCURSES_SHLIB2)
1825
1826 # values to use as strings
1827 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR')
1828
1829 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1830
1831 ### Now that we're done running tests, add the compiler-warnings, if any
1832 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1833
1834 ### Define substitutions for header files to avoid name-pollution
1835 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1836 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1837 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1838
1839 ################################################################################
1840 test "$use_database" = yes && \
1841 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1842
1843 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1844 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${DFT_ARG_SUFFIX}${cf_cv_abi_version}-config.1:man/MKncu_config.in"
1845
1846 if test x"$enable_pc_files" = xyes ; then \
1847 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1848 MAKE_PC_FILES=
1849 else
1850 MAKE_PC_FILES="#"
1851 fi
1852 AC_SUBST(MAKE_PC_FILES)
1853 AC_SUBST(cross_compiling)
1854
1855 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
1856 if test -n "$FALLBACK_LIST"
1857 then
1858         if test "$TIC_PATH" = unknown
1859         then
1860                 AC_MSG_WARN(no tic program found for fallbacks)
1861         fi
1862 fi
1863 AC_SUBST(TIC_PATH)
1864
1865 if test "x$cf_with_tests" != xno ; then
1866         MAKE_TESTS=
1867 else
1868         MAKE_TESTS="#"
1869 fi
1870 AC_SUBST(MAKE_TESTS)
1871
1872 ADAHTML_DIR=../../doc/html/ada
1873 AC_SUBST(ADAHTML_DIR)
1874
1875 SUB_SCRIPTS=
1876
1877 AC_OUTPUT( \
1878         include/MKterm.h.awk \
1879         include/curses.head:include/curses.h.in \
1880         include/ncurses_dll.h \
1881         include/termcap.h \
1882         include/unctrl.h \
1883         $SUB_SCRIPTS \
1884         $SUB_MAKEFILES \
1885         Makefile,[
1886 if test "x$cf_with_tests" != xno ; then
1887         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LINK"], test)
1888 fi
1889 CF_LIB_RULES($SRC_SUBDIRS)
1890
1891 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
1892 if test -z "$USE_OLD_MAKERULES" ; then
1893         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
1894 fi
1895 fi
1896 ],[
1897 ### Special initialization commands, used to pass information from the
1898 ### configuration-run into config.status
1899
1900 AWK="$AWK"
1901 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1902 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1903 ECHO_LINK="$ECHO_LINK"
1904 LDCONFIG="$LDCONFIG"
1905 LIBTOOL_VERSION="$LIBTOOL_VERSION"
1906 LIB_NAME="$LIB_NAME"
1907 LIB_PREFIX="$LIB_PREFIX"
1908 LIB_SUBSETS="$LIB_SUBSETS"
1909 LIB_SUFFIX="$LIB_SUFFIX"
1910 LIB_TRACING="$LIB_TRACING"
1911 LN_S="$LN_S"
1912 MAKE_TERMINFO="$MAKE_TERMINFO"
1913 NCURSES_MAJOR="$NCURSES_MAJOR"
1914 NCURSES_MINOR="$NCURSES_MINOR"
1915 NCURSES_OSPEED="$NCURSES_OSPEED"
1916 NCURSES_PATCH="$NCURSES_PATCH"
1917 SRC_SUBDIRS="$SRC_SUBDIRS"
1918 TERMINFO="$TERMINFO"
1919 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1920 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1921 TICS_NAME="$TICS_NAME"
1922 TIC_PATH="$TIC_PATH"
1923 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1924 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1925 TINFO_NAME="$TINFO_NAME"
1926 TINFO_SUFFIX="$TINFO_SUFFIX"
1927 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
1928 WITH_CURSES_H="$with_curses_h"
1929 WITH_ECHO="$with_echo"
1930 WITH_OVERWRITE="$with_overwrite"
1931 cf_LIST_MODELS="$cf_list_models"
1932 cf_cv_abi_version="$cf_cv_abi_version"
1933 cf_cv_do_relink="$cf_cv_do_relink"
1934 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1935 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1936 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1937 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1938 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1939 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
1940 cf_cv_rel_version="$cf_cv_rel_version"
1941 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1942 cf_cv_shared_soname='$cf_cv_shared_soname'
1943 cf_cv_shlib_version="$cf_cv_shlib_version"
1944 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1945 cf_cv_system_name="$cf_cv_system_name"
1946 cf_cv_term_driver="$with_term_driver"
1947 cf_with_ada="$cf_with_ada"
1948 cf_with_cxx_binding="$cf_with_cxx_binding"
1949 cf_with_manpages="$cf_with_manpages"
1950 cf_with_tests="$cf_with_tests"
1951 host="$host"
1952 target="$target"
1953
1954 ],cat)dnl
1955 ${MAKE:-make} preinstall