configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2009,2010 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.503 2010/08/07 20:00:17 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.13.20020210)
  38 AC_REVISION($Revision: 1.503 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44
  45 CF_WITH_REL_VERSION(NCURSES)
  46 CF_WITH_ABI_VERSION
  47
  48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
  49 AC_ARG_WITH(system-type,
  50 [  --with-system-type=XXX  test: override derived host system-type],
  51 [AC_MSG_WARN(overriding system type to $withval)
  52  cf_cv_system_name=$withval])
  53
  54 ###     Save the given $CFLAGS to allow user-override.
  55 cf_user_CFLAGS="$CFLAGS"
  56
  57 ###     Default install-location
  58 CF_CFG_DEFAULTS
  59
  60 ###     Checks for programs.
  61 AC_PROG_CC
  62 CF_GCC_VERSION
  63
  64 AC_PROG_CPP
  65 AC_PROG_GCC_TRADITIONAL
  66 CF_PROG_CC_C_O(CC)
  67 AC_ISC_POSIX
  68 CF_ANSI_CC_REQD
  69 CF_PROG_EXT
  70 CF_PROG_LDCONFIG
  71
  72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  73 dnl                             configure script by not letting us test if C++
  74 dnl                             is present, making this option necessary.
  75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  76 AC_ARG_WITH(cxx,
  77         [  --without-cxx           do not adjust ncurses bool to match C++],
  78         [cf_with_cxx=$withval],
  79         [cf_with_cxx=yes])
  80 AC_MSG_RESULT($cf_with_cxx)
  81 if test "X$cf_with_cxx" = Xno ; then
  82         CXX=""
  83         GXX=""
  84 else
  85         # with autoconf 2.13, we can change the error to a warning:
  86         pushdef([AC_MSG_ERROR],
  87                 [AC_MSG_RESULT(no)
  88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  90         AC_PROG_CXX
  91         popdef([AC_MSG_ERROR])dnl
  92         # autoconf 2.5x removed the error - by hardcoding it to g++.
  93         if test "$CXX" = "g++" ; then
  94                 AC_PATH_PROG(CXX,g++)
  95         fi
  96         if test "$CXX" = "g++" ; then
  97                 AC_MSG_WARN(ignoring hardcoded g++)
  98                 cf_with_cxx=no; CXX=""; GXX="";
  99         fi
 100 fi
 101
 102 CF_GXX_VERSION
 103 case $GXX_VERSION in
 104 1*|2.[[0-6]]*)
 105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 106         # cf_cxx_library=no
 107         AC_MSG_WARN(templates do not work)
 108         ;;
 109 esac
 110
 111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 112 AC_ARG_WITH(cxx-binding,
 113         [  --without-cxx-binding   do not build C++ binding and demo],
 114         [cf_with_cxx_binding=$withval],
 115         [cf_with_cxx_binding=$cf_with_cxx])
 116 AC_MSG_RESULT($cf_with_cxx_binding)
 117
 118 AC_MSG_CHECKING(if you want to build with Ada95)
 119 AC_ARG_WITH(ada,
 120         [  --without-ada           suppress check for Ada95, don't build demo],
 121         [cf_with_ada=$withval],
 122         [cf_with_ada=yes])
 123 AC_MSG_RESULT($cf_with_ada)
 124
 125 AC_MSG_CHECKING(if you want to install manpages)
 126 AC_ARG_WITH(manpages,
 127         [  --without-manpages      suppress install of manpages],
 128         [cf_with_manpages=$withval],
 129         [cf_with_manpages=yes])
 130 AC_MSG_RESULT($cf_with_manpages)
 131
 132 AC_MSG_CHECKING(if you want to build programs such as tic)
 133 AC_ARG_WITH(progs,
 134         [  --without-progs         suppress build with programs (e.g., tic)],
 135         [cf_with_progs=$withval],
 136         [cf_with_progs=yes])
 137 AC_MSG_RESULT($cf_with_progs)
 138
 139 AC_MSG_CHECKING(if you wish to install curses.h)
 140 AC_ARG_WITH(curses-h,
 141         [  --without-curses-h      install curses.h as ncurses.h only],
 142         [with_curses_h=$withval],
 143         [with_curses_h=yes])
 144 AC_MSG_RESULT($with_curses_h)
 145
 146 modules_to_build="ncurses"
 147 if test "X$cf_with_progs" != Xno ; then
 148 modules_to_build="$modules_to_build progs tack"
 149 fi
 150 modules_to_build="$modules_to_build panel menu form"
 151
 152 AC_ARG_PROGRAM
 153
 154 CF_PROG_AWK
 155 CF_PROG_EGREP
 156 CF_PROG_INSTALL
 157 CF_PROG_LINT
 158 CF_PROG_LN_S
 159
 160 AC_SYS_LONG_FILE_NAMES
 161
 162 # if we find pkg-config, check if we should install the ".pc" files.
 163 CF_PKG_CONFIG
 164
 165 if test "$PKG_CONFIG" != no ; then
 166         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
 167
 168         # Leave this as something that can be overridden in the environment.
 169         if test -z "$PKG_CONFIG_LIBDIR" ; then
 170                 PKG_CONFIG_LIBDIR=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`/lib/pkgconfig
 171         fi
 172         PKG_CONFIG_LIBDIR=`echo "$PKG_CONFIG_LIBDIR" | sed -e 's/^://' -e 's/:.*//'`
 173         if test -n "$PKG_CONFIG_LIBDIR" && test -d "$PKG_CONFIG_LIBDIR" ; then
 174                 AC_ARG_ENABLE(pc-files,
 175                         [  --enable-pc-files       generate and install .pc files for pkg-config],
 176                         [enable_pc_files=$enableval],
 177                         [enable_pc_files=no])
 178                 AC_MSG_RESULT($enable_pc_files)
 179         else
 180                 AC_MSG_RESULT(no)
 181                 AC_MSG_WARN(did not find library $PKG_CONFIG_LIBDIR)
 182                 enable_pc_files=no
 183         fi
 184 fi
 185 AC_SUBST(PKG_CONFIG_LIBDIR)
 186
 187 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 188 AC_ARG_ENABLE(mixed-case,
 189         [  --enable-mixed-case     tic should assume mixed-case filenames],
 190         [enable_mixedcase=$enableval],
 191         [enable_mixedcase=auto])
 192 AC_MSG_RESULT($enable_mixedcase)
 193 if test "$enable_mixedcase" = "auto" ; then
 194     CF_MIXEDCASE_FILENAMES
 195 else
 196     cf_cv_mixedcase=$enable_mixedcase
 197     if test "$enable_mixedcase" = "yes" ; then
 198         AC_DEFINE(MIXEDCASE_FILENAMES)
 199     fi
 200 fi
 201
 202 # do this after mixed-case option (tags/TAGS is not as important as tic).
 203 AC_PROG_MAKE_SET
 204 CF_MAKE_TAGS
 205 CF_MAKEFLAGS
 206
 207 dnl These are standard among *NIX systems, but not when cross-compiling
 208 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 209 AC_CHECK_TOOL(LD, ld, ld)
 210 AC_CHECK_TOOL(AR, ar, ar)
 211 CF_AR_FLAGS
 212
 213 dnl Special option for use by system-builders: the install-prefix is used to
 214 dnl adjust the location into which the actual install is done, so that an
 215 dnl archive can be built without modifying the host system's configuration.
 216 AC_MSG_CHECKING(if you have specified an install-prefix)
 217 AC_ARG_WITH(install-prefix,
 218         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 219         [case "$withval" in #(vi
 220         yes|no) #(vi
 221                 ;;
 222         *)      DESTDIR="$withval"
 223                 ;;
 224         esac])
 225 AC_MSG_RESULT($DESTDIR)
 226 AC_SUBST(DESTDIR)
 227
 228 ###############################################################################
 229 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 230 # If we're cross-compiling, allow the user to override the tools and their
 231 # options.  The configure script is oriented toward identifying the host
 232 # compiler, etc., but we need a build compiler to generate parts of the source.
 233 CF_BUILD_CC
 234
 235 ###############################################################################
 236 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 237
 238 ### Options to allow the user to specify the set of libraries which are used.
 239 ### Use "--without-normal --with-shared" to allow the default model to be
 240 ### shared, for example.
 241 cf_list_models=""
 242 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 243
 244 CF_WITH_LIBTOOL
 245 if test "$with_libtool" != "no" ; then
 246
 247 cf_list_models="$cf_list_models libtool"
 248
 249 else
 250
 251 AC_MSG_CHECKING(if you want to build shared libraries)
 252 AC_ARG_WITH(shared,
 253         [  --with-shared           generate shared-libraries],
 254         [with_shared=$withval],
 255         [with_shared=no])
 256 AC_MSG_RESULT($with_shared)
 257 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
 258
 259 AC_MSG_CHECKING(if you want to build static libraries)
 260 AC_ARG_WITH(normal,
 261         [  --with-normal           generate normal-libraries (default)],
 262         [with_normal=$withval],
 263         [with_normal=yes])
 264 AC_MSG_RESULT($with_normal)
 265 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
 266
 267 AC_MSG_CHECKING(if you want to build debug libraries)
 268 AC_ARG_WITH(debug,
 269         [  --with-debug            generate debug-libraries (default)],
 270         [with_debug=$withval],
 271         [with_debug=yes])
 272 AC_MSG_RESULT($with_debug)
 273 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
 274
 275 AC_MSG_CHECKING(if you want to build profiling libraries)
 276 AC_ARG_WITH(profile,
 277         [  --with-profile          generate profile-libraries],
 278         [with_profile=$withval],
 279         [with_profile=no])
 280 AC_MSG_RESULT($with_profile)
 281 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
 282
 283 fi
 284
 285 ###############################################################################
 286
 287 AC_MSG_CHECKING(for specified models)
 288 test -z "$cf_list_models" && cf_list_models=normal
 289 dnl If we use libtool to generate libraries, then it must be the only
 290 dnl specified model.
 291 test "$with_libtool" != "no" && cf_list_models=libtool
 292 AC_MSG_RESULT($cf_list_models)
 293
 294 ### Use the first model as the default, and save its suffix for use in building
 295 ### up test-applications.
 296 AC_MSG_CHECKING(for default model)
 297 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 298 AC_MSG_RESULT($DFT_LWR_MODEL)
 299
 300 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 301
 302 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 303 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 304
 305 TICS_NAME=tic
 306 AC_SUBST(TICS_NAME)
 307
 308 TINFO_NAME=tinfo
 309 AC_SUBST(TINFO_NAME)
 310
 311 LIB_NAME=ncurses
 312 AC_SUBST(LIB_NAME)
 313
 314 LIB_DIR=../lib
 315 LIB_2ND=../../lib
 316
 317 CF_LIB_PREFIX(cf_prefix)
 318 LIB_PREFIX=$cf_prefix
 319 AC_SUBST(LIB_PREFIX)
 320
 321 LIB_SUFFIX=
 322 AC_SUBST(LIB_SUFFIX)
 323
 324 ###############################################################################
 325
 326 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 327 AC_ARG_WITH(termlib,
 328         [  --with-termlib          generate separate terminfo library],
 329         [with_termlib=$withval],
 330         [with_termlib=no])
 331 AC_MSG_RESULT($with_termlib)
 332
 333 AC_MSG_CHECKING(if you want to build a separate tic library)
 334 AC_ARG_WITH(ticlib,
 335         [  --with-ticlib           generate separate tic library],
 336         [with_ticlib=$withval],
 337         [with_ticlib=no])
 338 AC_MSG_RESULT($with_ticlib)
 339
 340 ### Checks for special libraries, must be done up-front.
 341 SHLIB_LIST=""
 342 CF_WITH_GPM
 343 if test "$with_gpm" != no ; then
 344         AC_MSG_CHECKING(if you want to load GPM dynamically)
 345         AC_ARG_WITH(dlsym,
 346                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 347                 [with_dlsym=$withval],
 348                 [with_dlsym=yes])
 349         AC_MSG_RESULT($with_dlsym)
 350         if test "$with_dlsym" = yes ; then
 351                 CF_FUNC_DLSYM
 352                 if test "$with_gpm" != yes ; then
 353                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 354                         cf_cv_gpm_soname="$with_gpm"
 355                 else
 356                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 357                 fi
 358                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
 359                 SHLIB_LIST="-ldl $SHLIB_LIST"
 360         else
 361                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 362                 CF_ADD_LIB(gpm,TEST_LIBS)
 363         fi
 364         AC_DEFINE(HAVE_LIBGPM)
 365         CF_CHECK_GPM_WGETCH
 366 fi
 367
 368 CF_WITH_SYSMOUSE
 369
 370 dnl Not all ports of gcc support the -g option
 371
 372 if test X"$CC_G_OPT" = X"" ; then
 373         CC_G_OPT='-g'
 374         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
 375 fi
 376 AC_SUBST(CC_G_OPT)
 377
 378 if test X"$CXX_G_OPT" = X"" ; then
 379         CXX_G_OPT='-g'
 380         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
 381 fi
 382 AC_SUBST(CXX_G_OPT)
 383
 384 AC_MSG_CHECKING(for default loader flags)
 385 case $DFT_LWR_MODEL in
 386 libtool) LD_MODEL=''   ;;
 387 normal)  LD_MODEL=''   ;;
 388 debug)   LD_MODEL=$CC_G_OPT ;;
 389 profile) LD_MODEL='-pg';;
 390 shared)  LD_MODEL=''   ;;
 391 esac
 392 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 393 AC_MSG_RESULT($LD_MODEL)
 394
 395 case $DFT_LWR_MODEL in
 396 shared)
 397 CF_ENABLE_RPATH
 398 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 399 AC_ARG_ENABLE(relink,
 400 [  --disable-relink        relink shared libraries during install],
 401 [cf_cv_do_relink=$enableval],
 402 [cf_cv_do_relink=yes])
 403 AC_MSG_RESULT($cf_cv_do_relink)
 404         ;;
 405 esac
 406
 407 CF_SHARED_OPTS
 408 if test "$CC_SHARED_OPTS" = "unknown"; then
 409         for model in $cf_list_models; do
 410                 if test "$model" = "shared"; then
 411                         AC_ERROR(Shared libraries are not supported in this version)
 412                 fi
 413         done
 414 fi
 415
 416 ### If we're building with rpath, try to link non-standard libs that way too.
 417 if test "$DFT_LWR_MODEL" = "shared"; then
 418         CF_DISABLE_RPATH_HACK
 419 fi
 420
 421 ###############################################################################
 422 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 423
 424 ###     use option --disable-overwrite to leave out the link to -lcurses
 425 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 426 AC_ARG_ENABLE(overwrite,
 427         [  --disable-overwrite     leave out the link to -lcurses],
 428         [with_overwrite=$enableval],
 429         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 430 AC_MSG_RESULT($with_overwrite)
 431
 432 AC_MSG_CHECKING(if external terminfo-database is used)
 433 AC_ARG_ENABLE(database,
 434         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 435         [use_database=$enableval],
 436         [use_database=yes])
 437 AC_MSG_RESULT($use_database)
 438
 439 case $host_os in #(vi
 440 os2*) #(vi
 441         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 442         ;;
 443 *) #(vi
 444         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 445         ;;
 446 esac
 447 AC_SUBST(TERMINFO_SRC)
 448
 449 CF_PATHSEP
 450 if test "$use_database" != no ; then
 451         AC_DEFINE(USE_DATABASE)
 452
 453         AC_MSG_CHECKING(which terminfo source-file will be installed)
 454         AC_ARG_WITH(database,
 455                 [  --with-database=XXX     specify terminfo source to install],
 456                 [TERMINFO_SRC=$withval])
 457         AC_MSG_RESULT($TERMINFO_SRC)
 458
 459         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 460         AC_ARG_WITH(hashed-db,
 461                 [  --with-hashed-db        specify hashed-database library],,
 462                 [with_hashed_db=no])
 463         AC_MSG_RESULT($with_hashed_db)
 464 else
 465         with_hashed_db=no
 466 fi
 467
 468 AC_MSG_CHECKING(for list of fallback descriptions)
 469 AC_ARG_WITH(fallbacks,
 470         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 471         [with_fallback=$withval],
 472         [with_fallback=])
 473 AC_MSG_RESULT($with_fallback)
 474 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 475 AC_SUBST(FALLBACK_LIST)
 476
 477 AC_MSG_CHECKING(if you want modern xterm or antique)
 478 AC_ARG_WITH(xterm-new,
 479         [  --without-xterm-new     specify if xterm terminfo should be old version],
 480         [with_xterm_new=$withval],
 481         [with_xterm_new=yes])
 482 case $with_xterm_new in
 483 no)     with_xterm_new=xterm-old;;
 484 *)      with_xterm_new=xterm-new;;
 485 esac
 486 AC_MSG_RESULT($with_xterm_new)
 487 WHICH_XTERM=$with_xterm_new
 488 AC_SUBST(WHICH_XTERM)
 489
 490 MAKE_TERMINFO=
 491 if test "$use_database" = no ; then
 492         TERMINFO="${datadir}/terminfo"
 493         MAKE_TERMINFO="#"
 494 else
 495
 496 AC_MSG_CHECKING(for list of terminfo directories)
 497 CF_WITH_PATHLIST(terminfo-dirs,
 498         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 499         TERMINFO_DIRS,
 500         DATADIR/terminfo,
 501         ${datadir}/terminfo)
 502 AC_MSG_RESULT($TERMINFO_DIRS)
 503 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
 504
 505 AC_MSG_CHECKING(for default terminfo directory)
 506 CF_WITH_PATH(default-terminfo-dir,
 507         [  --with-default-terminfo-dir=DIR default terminfo directory],
 508         TERMINFO,
 509         DATADIR/terminfo,
 510         ${datadir}/terminfo)
 511 AC_MSG_RESULT($TERMINFO)
 512 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
 513
 514 fi
 515
 516 AC_SUBST(TERMINFO)
 517 AC_SUBST(MAKE_TERMINFO)
 518
 519 ###     use option --disable-big-core to make tic run on small machines
 520 ###     We need 4Mb, check if we can allocate 50% more than that.
 521 AC_MSG_CHECKING(if big-core option selected)
 522 AC_ARG_ENABLE(big-core,
 523         [  --disable-big-core      assume machine has little memory],
 524         [with_big_core=$enableval],
 525         [AC_TRY_RUN([
 526 #include <stdlib.h>
 527 #include <string.h>
 528 int main() {
 529         unsigned long n = 6000000L;
 530         char *s = malloc(n);
 531         if (s != 0)
 532                 s[0] = s[n-1] = 0;
 533         ${cf_cv_main_return:-return}(s == 0);
 534 }],
 535         [with_big_core=yes],
 536         [with_big_core=no],
 537         [with_big_core=no])])
 538 AC_MSG_RESULT($with_big_core)
 539 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
 540
 541 ### ISO C only guarantees 512-char strings, we have tables which load faster
 542 ### when constructed using "big" strings.  More than the C compiler, the awk
 543 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 544 AC_MSG_CHECKING(if big-strings option selected)
 545 AC_ARG_ENABLE(big-strings,
 546         [  --disable-big-strings   assume compiler has only standard-size strings],
 547         [with_big_strings=$enableval],
 548         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 549 AC_MSG_RESULT($with_big_strings)
 550
 551 USE_BIG_STRINGS=0
 552 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
 553 AC_SUBST(USE_BIG_STRINGS)
 554
 555 ###     use option --enable-termcap to compile in the termcap fallback support
 556 AC_MSG_CHECKING(if you want termcap-fallback support)
 557 AC_ARG_ENABLE(termcap,
 558         [  --enable-termcap        compile in termcap fallback support],
 559         [with_termcap=$enableval],
 560         [with_termcap=no])
 561 AC_MSG_RESULT($with_termcap)
 562
 563 if test "$with_termcap" != "yes" ; then
 564         if test "$use_database" = no ; then
 565                 if test -z "$with_fallback" ; then
 566                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 567                 fi
 568         fi
 569         AC_DEFINE(PURE_TERMINFO)
 570 else
 571
 572 if test "$with_ticlib" != no ; then
 573         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 574 fi
 575
 576 AC_DEFINE(USE_TERMCAP)
 577 AC_MSG_CHECKING(for list of termcap files)
 578 CF_WITH_PATHLIST(termpath,
 579         [  --with-termpath=XXX     specify list of termcap files],
 580         TERMPATH,
 581         /etc/termcap:/usr/share/misc/termcap)
 582 AC_MSG_RESULT($TERMPATH)
 583 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
 584
 585 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 586 AC_MSG_CHECKING(if fast termcap-loader is needed)
 587 AC_ARG_ENABLE(getcap,
 588         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 589         [with_getcap=$enableval],
 590         [with_getcap=no])
 591 AC_MSG_RESULT($with_getcap)
 592 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
 593
 594 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 595 AC_ARG_ENABLE(getcap-cache,
 596         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 597         [with_getcap_cache=$enableval],
 598         [with_getcap_cache=no])
 599 AC_MSG_RESULT($with_getcap_cache)
 600 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
 601
 602 fi
 603
 604 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 605 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 606 AC_ARG_ENABLE(home-terminfo,
 607         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 608         [with_home_terminfo=$enableval],
 609         [with_home_terminfo=yes])
 610 AC_MSG_RESULT($with_home_terminfo)
 611 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
 612
 613 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 614 AC_ARG_ENABLE(root-environ,
 615         [  --disable-root-environ  restrict environment when running as root],
 616         [with_root_environ=$enableval],
 617         [with_root_environ=yes])
 618 AC_MSG_RESULT($with_root_environ)
 619 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
 620
 621 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 622 ###   to reduce storage requirements for the terminfo database.
 623 CF_LINK_FUNCS
 624
 625 with_links=no
 626 with_symlinks=no
 627
 628 # soft links (symbolic links) are useful for some systems where hard links do
 629 # not work, or to make it simpler to copy terminfo trees around.
 630 if test "$ac_cv_func_symlink" = yes ; then
 631     AC_MSG_CHECKING(if tic should use symbolic links)
 632     AC_ARG_ENABLE(symlinks,
 633         [  --enable-symlinks       make tic use symbolic links not hard links],
 634         [with_symlinks=$enableval],
 635         [with_symlinks=no])
 636     AC_MSG_RESULT($with_symlinks)
 637 fi
 638
 639 # If we have hard links and did not choose to use soft links instead, there is
 640 # no reason to make this choice optional - use the hard links.
 641 if test "$with_symlinks" = no ; then
 642     AC_MSG_CHECKING(if tic should use hard links)
 643     if test "$ac_cv_func_link" = yes ; then
 644         with_links=yes
 645     else
 646         with_links=no
 647     fi
 648     AC_MSG_RESULT($with_links)
 649 fi
 650
 651 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
 652 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
 653
 654 ###   use option --enable-broken-linker to force on use of broken-linker support
 655 AC_MSG_CHECKING(if you want broken-linker support code)
 656 AC_ARG_ENABLE(broken_linker,
 657         [  --enable-broken_linker  compile with broken-linker support code],
 658         [with_broken_linker=$enableval],
 659         [with_broken_linker=${BROKEN_LINKER-no}])
 660 AC_MSG_RESULT($with_broken_linker)
 661
 662 BROKEN_LINKER=0
 663 if test "$with_broken_linker" = yes ; then
 664         AC_DEFINE(BROKEN_LINKER)
 665         BROKEN_LINKER=1
 666 elif test "$DFT_LWR_MODEL" = shared ; then
 667         case $cf_cv_system_name in #(vi
 668         cygwin*)
 669                 AC_DEFINE(BROKEN_LINKER)
 670                 BROKEN_LINKER=1
 671                 CF_VERBOSE(cygwin linker is broken anyway)
 672                 ;;
 673         esac
 674 fi
 675 AC_SUBST(BROKEN_LINKER)
 676
 677 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 678 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 679 AC_ARG_ENABLE(bsdpad,
 680         [  --enable-bsdpad         recognize BSD-style prefix padding],
 681         [with_bsdpad=$enableval],
 682         [with_bsdpad=no])
 683 AC_MSG_RESULT($with_bsdpad)
 684 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
 685
 686 ###   use option --enable-widec to turn on use of wide-character support
 687 NCURSES_CH_T=chtype
 688 NCURSES_LIBUTF8=0
 689
 690 NEED_WCHAR_H=0
 691 NCURSES_MBSTATE_T=0
 692 NCURSES_WCHAR_T=0
 693 NCURSES_WINT_T=0
 694
 695 # Check to define _XOPEN_SOURCE "automatically"
 696 CF_XOPEN_SOURCE(500)
 697
 698 # Work around breakage on OS X
 699 CF_SIGWINCH
 700
 701 # Checks for CODESET support.
 702 AM_LANGINFO_CODESET
 703
 704 # use these variables to work around a defect in gcc's fixincludes.
 705 NCURSES_OK_WCHAR_T=
 706 NCURSES_OK_WINT_T=
 707
 708 AC_MSG_CHECKING(if you want wide-character code)
 709 AC_ARG_ENABLE(widec,
 710         [  --enable-widec          compile with wide-char/UTF-8 code],
 711         [with_widec=$enableval],
 712         [with_widec=no])
 713 AC_MSG_RESULT($with_widec)
 714 if test "$with_widec" = yes ; then
 715         LIB_SUFFIX="w${LIB_SUFFIX}"
 716         AC_DEFINE(USE_WIDEC_SUPPORT)
 717
 718         case "$CFLAGS $CPPFLAGS" in #(vi
 719         *-D_XOPEN_SOURCE=500) #(vi
 720                 ;;
 721         *)
 722                 CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 723                 ;;
 724         esac
 725
 726         # with_overwrite=no
 727         NCURSES_CH_T=cchar_t
 728         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 729         if test "$ac_cv_func_putwc" != yes ; then
 730                 CF_UTF8_LIB
 731                 if test "$cf_cv_utf8_lib" != no ; then
 732                         NCURSES_LIBUTF8=1
 733                 fi
 734         fi
 735         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 736         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 737         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 738
 739         if test "$NCURSES_MBSTATE_T" != 0; then
 740                 AC_DEFINE(NEED_MBSTATE_T_DEF)
 741         fi
 742 fi
 743 AC_SUBST(NCURSES_CH_T)
 744 AC_SUBST(NCURSES_LIBUTF8)
 745
 746 AC_SUBST(NEED_WCHAR_H)
 747 AC_SUBST(NCURSES_MBSTATE_T)
 748 AC_SUBST(NCURSES_WCHAR_T)
 749 AC_SUBST(NCURSES_WINT_T)
 750
 751 AC_SUBST(NCURSES_OK_WCHAR_T)
 752 AC_SUBST(NCURSES_OK_WINT_T)
 753
 754 ###   use option --disable-lp64 to allow long chtype
 755 case $cf_cv_abi_version in
 756 [[345]]*)
 757         default_with_lp64=no
 758         ;;
 759 *)
 760         default_with_lp64=yes
 761         ;;
 762 esac
 763
 764 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 765 AC_ARG_ENABLE(lp64,
 766         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 767         [with_lp64=$enableval],
 768         [with_lp64=$default_with_lp64])
 769 AC_MSG_RESULT($with_lp64)
 770
 771 if test "$with_lp64" = yes ; then
 772         cf_cv_enable_lp64=1
 773 else
 774         cf_cv_enable_lp64=0
 775 fi
 776 AC_SUBST(cf_cv_enable_lp64)
 777
 778 CF_LARGEFILE
 779
 780 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 781 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 782 AC_ARG_ENABLE(tparm-varargs,
 783         [  --disable-tparm-varargs compile tparm() without varargs interface],
 784         [with_tparm_varargs=$enableval],
 785         [with_tparm_varargs=yes])
 786 AC_MSG_RESULT($with_tparm_varargs)
 787 NCURSES_TPARM_VARARGS=0
 788 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
 789 AC_SUBST(NCURSES_TPARM_VARARGS)
 790
 791 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 792 if test "$with_ticlib" != no ; then
 793 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 794 AC_ARG_ENABLE(tic-depends,
 795         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 796         [with_tic_depends=$enableval],
 797         [with_tic_depends=yes])
 798 AC_MSG_RESULT($with_tic_depends)
 799 else
 800         with_tic_depends=no
 801 fi
 802
 803 ###   use option --with-bool to override bool's type
 804 AC_MSG_CHECKING(for type of bool)
 805 AC_ARG_WITH(bool,
 806         [  --with-bool=TYPE        override fallback type of bool variable],
 807         [NCURSES_BOOL="$withval"],
 808         [NCURSES_BOOL=auto])
 809 AC_MSG_RESULT($NCURSES_BOOL)
 810 AC_SUBST(NCURSES_BOOL)
 811
 812 AC_MSG_CHECKING(for alternate terminal capabilities file)
 813 AC_ARG_WITH(caps,
 814         [  --with-caps=alt         compile with alternate Caps file],
 815         [TERMINFO_CAPS=Caps.$withval],
 816         [TERMINFO_CAPS=Caps])
 817 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 818 AC_MSG_RESULT($TERMINFO_CAPS)
 819 AC_SUBST(TERMINFO_CAPS)
 820
 821 ###   use option --with-chtype to override chtype's type
 822 AC_MSG_CHECKING(for type of chtype)
 823 AC_ARG_WITH(chtype,
 824         [  --with-chtype=TYPE      override type of chtype],
 825         [NCURSES_CHTYPE="$withval"],
 826         [NCURSES_CHTYPE=auto])
 827 AC_MSG_RESULT($NCURSES_CHTYPE)
 828
 829 ###   use option --with-ospeed to override ospeed's type
 830 AC_MSG_CHECKING(for type of ospeed)
 831 AC_ARG_WITH(ospeed,
 832         [  --with-ospeed=TYPE      override type of ospeed variable],
 833         [NCURSES_OSPEED="$withval"],
 834         [NCURSES_OSPEED=short])
 835 AC_MSG_RESULT($NCURSES_OSPEED)
 836 AC_SUBST(NCURSES_OSPEED)
 837
 838 ###   use option --with-mmask-t to override mmask_t's type
 839 AC_MSG_CHECKING(for type of mmask_t)
 840 AC_ARG_WITH(mmask-t,
 841         [  --with-mmask-t=TYPE     override type of mmask_t],
 842         [NCURSES_MMASK_T="$withval"],
 843         [NCURSES_MMASK_T=auto])
 844 AC_MSG_RESULT($NCURSES_MMASK_T)
 845
 846 ###   use option --with-ccharw-max to override CCHARW_MAX size
 847 AC_MSG_CHECKING(for size CCHARW_MAX)
 848 AC_ARG_WITH(ccharw-max,
 849         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
 850         [NCURSES_CCHARW_MAX="$withval"],
 851         [NCURSES_CCHARW_MAX=5])
 852 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
 853 AC_SUBST(NCURSES_CCHARW_MAX)
 854
 855 ### Enable compiling-in rcs id's
 856 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
 857 AC_ARG_WITH(rcs-ids,
 858         [  --with-rcs-ids          compile-in RCS identifiers],
 859         [with_rcs_ids=$withval],
 860         [with_rcs_ids=no])
 861 AC_MSG_RESULT($with_rcs_ids)
 862 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
 863
 864 ###############################################################################
 865 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
 866
 867 ###############################################################################
 868 CF_HELP_MESSAGE(Extensions:)
 869
 870 ### Note that some functions (such as const) are normally disabled anyway.
 871 AC_MSG_CHECKING(if you want to build with function extensions)
 872 AC_ARG_ENABLE(ext-funcs,
 873         [  --disable-ext-funcs     disable function-extensions],
 874         [with_ext_funcs=$enableval],
 875         [with_ext_funcs=yes])
 876 AC_MSG_RESULT($with_ext_funcs)
 877 if test "$with_ext_funcs" = yes ; then
 878         NCURSES_EXT_FUNCS=1
 879         AC_DEFINE(HAVE_CURSES_VERSION)
 880         AC_DEFINE(HAVE_HAS_KEY)
 881         AC_DEFINE(HAVE_RESIZETERM)
 882         AC_DEFINE(HAVE_RESIZE_TERM)
 883         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
 884         AC_DEFINE(HAVE_WRESIZE)
 885         AC_DEFINE(NCURSES_EXT_FUNCS)
 886         GENERATED_EXT_FUNCS=generated
 887 else
 888         NCURSES_EXT_FUNCS=0
 889         GENERATED_EXT_FUNCS=
 890 fi
 891 AC_SUBST(NCURSES_EXT_FUNCS)
 892 AC_SUBST(GENERATED_EXT_FUNCS)
 893
 894 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
 895 AC_ARG_ENABLE(sp-funcs,
 896         [  --enable-sp-funcs       enable experimental SCREEN-extensions],
 897         [with_sp_funcs=$enableval],
 898         [with_sp_funcs=no])
 899 AC_MSG_RESULT($with_sp_funcs)
 900 if test "$with_sp_funcs" = yes ; then
 901         NCURSES_SP_FUNCS=1
 902         AC_DEFINE(NCURSES_SP_FUNCS)
 903         GENERATED_SP_FUNCS=generated
 904 else
 905         NCURSES_SP_FUNCS=0
 906         GENERATED_SP_FUNCS=
 907 fi
 908 AC_SUBST(NCURSES_SP_FUNCS)
 909 AC_SUBST(GENERATED_SP_FUNCS)
 910
 911 AC_MSG_CHECKING(if you want to build with experimental terminal-driver)
 912 AC_ARG_ENABLE(term-driver,
 913         [  --enable-term-driver    enable experimental terminal-driver],
 914         [with_term_driver=$enableval],
 915         [with_term_driver=no])
 916 AC_MSG_RESULT($with_term_driver)
 917 if test "$with_term_driver" = yes ; then
 918         AC_DEFINE(USE_TERM_DRIVER)
 919         if test "$with_sp_funcs" != yes ; then
 920                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
 921         fi
 922 fi
 923
 924 ###   use option --enable-const to turn on use of const beyond that in XSI.
 925 AC_MSG_CHECKING(for extended use of const keyword)
 926 AC_ARG_ENABLE(const,
 927         [  --enable-const          compile with extra/non-standard const],
 928         [with_ext_const=$enableval],
 929         [with_ext_const=no])
 930 AC_MSG_RESULT($with_ext_const)
 931 NCURSES_CONST='/*nothing*/'
 932 if test "$with_ext_const" = yes ; then
 933         NCURSES_CONST=const
 934 fi
 935 AC_SUBST(NCURSES_CONST)
 936
 937 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
 938 AC_MSG_CHECKING(if you want to use extended colors)
 939 AC_ARG_ENABLE(ext-colors,
 940         [  --enable-ext-colors     compile for 256-color support],
 941         [with_ext_colors=$enableval],
 942         [with_ext_colors=no])
 943 AC_MSG_RESULT($with_ext_colors)
 944 NCURSES_EXT_COLORS=0
 945 if test "$with_ext_colors" = yes ; then
 946         if test "$with_widec" != yes ; then
 947                 AC_MSG_ERROR(This option applies only to wide-character library)
 948         else
 949                 # cannot be ABI 5 since it changes sizeof(cchar_t)
 950                 CF_NCURSES_ABI_6
 951         fi
 952         NCURSES_EXT_COLORS=1
 953         AC_DEFINE(NCURSES_EXT_COLORS)
 954 fi
 955 AC_SUBST(NCURSES_EXT_COLORS)
 956
 957 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
 958 AC_MSG_CHECKING(if you want to use extended mouse encoding)
 959 AC_ARG_ENABLE(ext-mouse,
 960         [  --enable-ext-mouse      compile for extended mouse-encoding],
 961         [with_ext_mouse=$enableval],
 962         [with_ext_mouse=no])
 963 AC_MSG_RESULT($with_ext_mouse)
 964 NCURSES_MOUSE_VERSION=1
 965 if test "$with_ext_mouse" = yes ; then
 966         NCURSES_MOUSE_VERSION=2
 967         CF_NCURSES_ABI_6
 968 fi
 969 AC_SUBST(NCURSES_MOUSE_VERSION)
 970
 971 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
 972 AC_ARG_ENABLE(no-padding,
 973         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
 974         [with_no_padding=$enableval],
 975         [with_no_padding=$with_ext_funcs])
 976 AC_MSG_RESULT($with_no_padding)
 977 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
 978
 979 AC_CHECK_SIZEOF([signed char], 0)
 980 if test "$ac_cv_sizeof_signed_char" = 1 ; then
 981         NCURSES_SBOOL="signed char"
 982 else
 983         NCURSES_SBOOL="char"
 984 fi
 985 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
 986 AC_ARG_ENABLE(signed-char,
 987         [  --enable-signed-char    compile using signed Boolean's in term.h],
 988         [with_signed_char=$enableval],
 989         [with_signed_char=no])
 990 AC_MSG_RESULT($with_signed_char)
 991 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
 992 AC_SUBST(NCURSES_SBOOL)
 993
 994 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
 995 AC_MSG_CHECKING(if you want SIGWINCH handler)
 996 AC_ARG_ENABLE(sigwinch,
 997         [  --enable-sigwinch       compile with SIGWINCH handler],
 998         [with_sigwinch=$enableval],
 999         [with_sigwinch=$with_ext_funcs])
1000 AC_MSG_RESULT($with_sigwinch)
1001 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
1002
1003 ###   use option --enable-tcap-names to allow user to define new capabilities
1004 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1005 AC_ARG_ENABLE(tcap-names,
1006         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1007         [with_tcap_names=$enableval],
1008         [with_tcap_names=$with_ext_funcs])
1009 AC_MSG_RESULT($with_tcap_names)
1010 NCURSES_XNAMES=0
1011 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
1012 AC_SUBST(NCURSES_XNAMES)
1013
1014 ###############################################################################
1015 # These options are relatively safe to experiment with.
1016 CF_HELP_MESSAGE(Development Code:)
1017 AC_MSG_CHECKING(if you want all development code)
1018 AC_ARG_WITH(develop,
1019         [  --without-develop       disable development options],
1020         [with_develop=$withval],
1021         [with_develop=no])
1022 AC_MSG_RESULT($with_develop)
1023
1024 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1025 AC_MSG_CHECKING(if you want hard-tabs code)
1026 AC_ARG_ENABLE(hard-tabs,
1027         [  --enable-hard-tabs      compile with hard-tabs code],,
1028         [enable_hard_tabs=$with_develop])
1029 AC_MSG_RESULT($enable_hard_tabs)
1030 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
1031
1032 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1033 AC_MSG_CHECKING(if you want limited support for xmc)
1034 AC_ARG_ENABLE(xmc-glitch,
1035         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1036         [enable_xmc_glitch=$with_develop])
1037 AC_MSG_RESULT($enable_xmc_glitch)
1038 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
1039
1040 ###############################################################################
1041 # These are just experimental, probably should not be in a package:
1042 CF_HELP_MESSAGE(Experimental Code:)
1043
1044 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1045 AC_ARG_ENABLE(assumed-color,
1046         [  --disable-assumed-color do not assume anything about default-colors],
1047         [with_assumed_color=$enableval],
1048         [with_assumed_color=yes])
1049 AC_MSG_RESULT($with_assumed_color)
1050 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
1051
1052 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1053 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1054 AC_ARG_ENABLE(hashmap,
1055         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1056         [with_hashmap=$enableval],
1057         [with_hashmap=yes])
1058 AC_MSG_RESULT($with_hashmap)
1059 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
1060
1061 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1062 AC_MSG_CHECKING(if you want colorfgbg code)
1063 AC_ARG_ENABLE(colorfgbg,
1064         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1065         [with_colorfgbg=$enableval],
1066         [with_colorfgbg=no])
1067 AC_MSG_RESULT($with_colorfgbg)
1068 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
1069
1070 ###   use option --enable-interop to turn on use of bindings used for interop
1071 AC_MSG_CHECKING(if you want interop bindings)
1072 AC_ARG_ENABLE(interop,
1073         [  --enable-interop        compile-in experimental interop bindings],
1074         [with_exp_interop=$enableval],
1075         [with_exp_interop=no])
1076 AC_MSG_RESULT($with_exp_interop)
1077
1078 NCURSES_INTEROP_FUNCS=0
1079 test "$with_exp_interop" = yes && NCURSES_INTEROP_FUNCS=1
1080 AC_SUBST(NCURSES_INTEROP_FUNCS)
1081
1082 # This is still experimental (20080329), but should ultimately be moved to
1083 # the script-block --with-normal, etc.
1084 CF_WITH_PTHREAD
1085
1086 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1087 AC_ARG_ENABLE(pthreads-eintr,
1088     [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1089     [use_pthreads_eintr=$enableval],
1090     [use_pthreads_eintr=no])
1091 AC_MSG_RESULT($use_pthreads_eintr)
1092 if test $use_pthreads_eintr = yes ; then
1093     AC_DEFINE(USE_PTHREADS_EINTR)
1094 fi
1095
1096 AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1097 AC_ARG_ENABLE(weak-symbols,
1098     [  --enable-weak-symbols   enable weak-symbols for pthreads],
1099     [use_weak_symbols=$enableval],
1100     [use_weak_symbols=no])
1101 AC_MSG_RESULT($use_weak_symbols)
1102 if test "$use_weak_symbols" = yes ; then
1103     CF_WEAK_SYMBOLS
1104 else
1105     cf_cv_weak_symbols=no
1106 fi
1107
1108 if test $cf_cv_weak_symbols = yes ; then
1109     AC_DEFINE(USE_WEAK_SYMBOLS)
1110 fi
1111
1112 PTHREAD=
1113 if test "$with_pthread" = "yes" ; then
1114     AC_DEFINE(USE_PTHREADS)
1115     enable_reentrant=yes
1116     if test $cf_cv_weak_symbols = yes ; then
1117         PTHREAD=-lpthread
1118     fi
1119 fi
1120 AC_SUBST(PTHREAD)
1121
1122 # Reentrant code has to be opaque; there's little advantage to making ncurses
1123 # opaque outside of that, so there is no --enable-opaque option.  We can use
1124 # this option without --with-pthreads, but this will be always set for
1125 # pthreads.
1126 AC_MSG_CHECKING(if you want experimental reentrant code)
1127 AC_ARG_ENABLE(reentrant,
1128         [  --enable-reentrant      compile with experimental reentrant code],
1129         [with_reentrant=$enableval],
1130         [with_reentrant=no])
1131 AC_MSG_RESULT($with_reentrant)
1132 if test "$with_reentrant" = yes ; then
1133         cf_cv_enable_reentrant=1
1134         cf_cv_enable_opaque="NCURSES_INTERNALS"
1135         NCURSES_OPAQUE=1
1136         NCURSES_SIZE_T=int
1137         if test $cf_cv_weak_symbols = yes ; then
1138                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1139                 CF_ADD_LIB(pthread,TEST_LIBS)
1140                 CF_ADD_LIB(pthread,TEST_LIBS2)
1141         fi
1142         LIB_SUFFIX="t${LIB_SUFFIX}"
1143         AC_DEFINE(USE_REENTRANT)
1144         CF_NCURSES_ABI_6
1145 else
1146         cf_cv_enable_reentrant=0
1147         cf_cv_enable_opaque="NCURSES_OPAQUE"
1148         NCURSES_OPAQUE=0
1149         NCURSES_SIZE_T=short
1150 fi
1151 AC_SUBST(cf_cv_enable_reentrant)
1152 AC_SUBST(cf_cv_enable_opaque)
1153 AC_SUBST(NCURSES_OPAQUE)
1154 AC_SUBST(NCURSES_SIZE_T)
1155
1156 ### Allow using a different wrap-prefix
1157 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1158         AC_MSG_CHECKING(for prefix used to wrap public variables)
1159         AC_ARG_WITH(wrap-prefix,
1160                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1161                 [NCURSES_WRAP_PREFIX=$withval],
1162                 [NCURSES_WRAP_PREFIX=_nc_])
1163         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1164 else
1165         NCURSES_WRAP_PREFIX=_nc_
1166 fi
1167 AC_SUBST(NCURSES_WRAP_PREFIX)
1168 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX")
1169
1170 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1171 AC_ARG_ENABLE(safe-sprintf,
1172         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1173         [with_safe_sprintf=$enableval],
1174         [with_safe_sprintf=no])
1175 AC_MSG_RESULT($with_safe_sprintf)
1176 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1177
1178 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1179 # when hashmap is used scroll hints are useless
1180 if test "$with_hashmap" = no ; then
1181 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1182 AC_ARG_ENABLE(scroll-hints,
1183         [  --disable-scroll-hints  compile without scroll-hints code],
1184         [with_scroll_hints=$enableval],
1185         [with_scroll_hints=yes])
1186 AC_MSG_RESULT($with_scroll_hints)
1187 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1188 fi
1189
1190 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1191 AC_ARG_ENABLE(wgetch-events,
1192         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1193         [with_wgetch_events=$enableval],
1194         [with_wgetch_events=no])
1195 AC_MSG_RESULT($with_wgetch_events)
1196 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1197
1198 ###############################################################################
1199 CF_HELP_MESSAGE(Testing/development Options:)
1200
1201 ###     use option --disable-echo to suppress full display compiling commands
1202 AC_MSG_CHECKING(if you want to display full commands during build)
1203 AC_ARG_ENABLE(echo,
1204         [  --enable-echo           build: display "compiling" commands (default)],
1205         [with_echo=$enableval],
1206         [with_echo=yes])
1207 if test "$with_echo" = yes; then
1208         ECHO_LINK=
1209 else
1210         ECHO_LINK='@ echo linking $@ ... ;'
1211         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1212         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1213 fi
1214 AC_MSG_RESULT($with_echo)
1215 AC_SUBST(ECHO_LINK)
1216
1217 ###     use option --enable-warnings to turn on all gcc warnings
1218 AC_MSG_CHECKING(if you want to see compiler warnings)
1219 AC_ARG_ENABLE(warnings,
1220         [  --enable-warnings       build: turn on GCC compiler warnings],
1221         [with_warnings=$enableval])
1222 AC_MSG_RESULT($with_warnings)
1223
1224 if test "x$with_warnings" = "xyes"; then
1225         CF_ADD_ADAFLAGS(-gnatg)
1226         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1227         if test "$cf_with_cxx" = yes ; then
1228                 CF_GXX_WARNINGS(Wno-unused)
1229         fi
1230 fi
1231 CF_GCC_ATTRIBUTES
1232
1233 ###     use option --enable-assertions to turn on generation of assertion code
1234 AC_MSG_CHECKING(if you want to enable runtime assertions)
1235 AC_ARG_ENABLE(assertions,
1236         [  --enable-assertions     test: turn on generation of assertion code],
1237         [with_assertions=$enableval],
1238         [with_assertions=no])
1239 AC_MSG_RESULT($with_assertions)
1240 if test -n "$GCC"
1241 then
1242         if test "$with_assertions" = no
1243         then
1244                 AC_DEFINE(NDEBUG)
1245                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1246         else
1247                 CF_ADD_ADAFLAGS(-gnata)
1248         fi
1249 fi
1250
1251 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1252 CF_DISABLE_LEAKS
1253 AC_DEFINE(HAVE_NC_ALLOC_H)
1254
1255 ###     use option --enable-expanded to generate certain macros as functions
1256 AC_ARG_ENABLE(expanded,
1257         [  --enable-expanded       test: generate functions for certain macros],
1258         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1259
1260 ###     use option --disable-macros to suppress macros in favor of functions
1261 AC_ARG_ENABLE(macros,
1262         [  --disable-macros        test: use functions rather than macros],
1263         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1264
1265 # Normally we only add trace() to the debug-library.  Allow this to be
1266 # extended to all models of the ncurses library:
1267 cf_all_traces=no
1268 case "$CFLAGS $CPPFLAGS" in
1269 *-DTRACE*)
1270         cf_all_traces=yes
1271         ;;
1272 esac
1273
1274 AC_MSG_CHECKING(whether to add trace feature to all models)
1275 AC_ARG_WITH(trace,
1276 [  --with-trace            test: add trace() function to all models of ncurses],
1277 [cf_with_trace=$withval],
1278 [cf_with_trace=$cf_all_traces])
1279 AC_MSG_RESULT($cf_with_trace)
1280
1281 if test "$cf_with_trace" = yes ; then
1282         LIB_TRACING=all
1283         ADA_TRACE=TRUE
1284         CF_ADD_CFLAGS(-DTRACE)
1285 else
1286         LIB_TRACING=DEBUG
1287         ADA_TRACE=FALSE
1288 fi
1289
1290 AC_SUBST(ADA_TRACE)
1291
1292 ###     Checks for libraries.
1293 case $cf_cv_system_name in #(vi
1294 *mingw32*) #(vi
1295         ;;
1296 *)
1297 AC_CHECK_FUNC(gettimeofday,
1298         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1299
1300 AC_CHECK_LIB(bsd, gettimeofday,
1301         AC_DEFINE(HAVE_GETTIMEOFDAY)
1302         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1303         ;;
1304 esac
1305
1306 CF_MATH_LIB(MATH_LIB,sin(x))
1307 AC_SUBST(MATH_LIB)
1308
1309 ###     Checks for header files.
1310 AC_STDC_HEADERS
1311 AC_HEADER_DIRENT
1312 AC_HEADER_TIME
1313 CF_REGEX
1314
1315 dnl These are some other potentially nonportable headers.
1316 AC_CHECK_HEADERS( \
1317 fcntl.h \
1318 getopt.h \
1319 limits.h \
1320 locale.h \
1321 poll.h \
1322 sys/bsdtypes.h \
1323 sys/ioctl.h \
1324 sys/param.h \
1325 sys/poll.h \
1326 sys/select.h \
1327 sys/time.h \
1328 sys/times.h \
1329 ttyent.h \
1330 unistd.h \
1331 wctype.h \
1332 )
1333
1334 # check for ISC (this may also define _POSIX_SOURCE)
1335 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1336 if test "$ISC" = yes ; then
1337         AC_CHECK_LIB(cposix,main)
1338         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1339 fi
1340
1341 CF_SYS_TIME_SELECT
1342
1343 ###     checks for compiler characteristics
1344 AC_LANG_C
1345 AC_C_CONST
1346 CF_C_INLINE(NCURSES_INLINE,1200)
1347 CF_SIG_ATOMIC_T
1348
1349 if test $NCURSES_CHTYPE = auto ; then
1350         CF_TYPEOF_CHTYPE
1351 else
1352         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1353 fi
1354 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1355 AC_SUBST(cf_cv_typeof_chtype)
1356
1357 CF_UNSIGNED_LITERALS
1358 cf_cv_1UL="1"
1359 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1360 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1361 AC_SUBST(cf_cv_1UL)
1362
1363 if test $NCURSES_MMASK_T = auto ; then
1364         cf_cv_typeof_mmask_t=long
1365 else
1366         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1367 fi
1368 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1369 AC_SUBST(cf_cv_typeof_mmask_t)
1370
1371 ###     Checks for external-data
1372 CF_ERRNO
1373 CF_LINK_DATAONLY
1374
1375 ###     Checks for library functions.
1376 AC_CHECK_FUNCS( \
1377 getcwd \
1378 getegid \
1379 geteuid \
1380 getttynam \
1381 issetugid \
1382 poll \
1383 remove \
1384 select \
1385 setbuf \
1386 setbuffer \
1387 setvbuf \
1388 sigaction \
1389 sigvec \
1390 strdup \
1391 strstr \
1392 tcgetpgrp \
1393 times \
1394 vsnprintf \
1395 )
1396 if test "$with_getcap" = "yes" ; then
1397         CF_CGETENT
1398 fi
1399
1400 CF_ISASCII
1401 CF_STRUCT_SIGACTION
1402 CF_FUNC_NANOSLEEP
1403 CF_FUNC_TERMIOS
1404 CF_FUNC_VSSCANF
1405 CF_MKSTEMP
1406
1407 # setup for prototype of fallback for vsscanf()
1408 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1409
1410 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1411 if test "$cross_compiling" = yes ; then
1412         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1413 else
1414         AC_FUNC_SETVBUF_REVERSED
1415 fi
1416 AC_TYPE_SIGNAL
1417 CF_TYPE_SIGACTION
1418 CF_SIZECHANGE
1419 CF_FUNC_MEMMOVE
1420 CF_FUNC_POLL
1421 CF_VA_COPY
1422 AC_FUNC_VFORK
1423
1424 # special check for test/ditto.c
1425 CF_FUNC_OPENPTY
1426 if test "$cf_cv_func_openpty" != no ; then
1427     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1428     AC_DEFINE(USE_XTERM_PTY)
1429     if test "$cf_cv_lib_util" = yes ; then
1430         CF_ADD_LIB(util,TEST_LIBS)
1431     fi
1432 fi
1433 AC_SUBST(TEST_LIBS)
1434 AC_SUBST(TEST_LIBS2)
1435
1436 if test "$with_hashed_db" != no ; then
1437         AC_DEFINE(USE_HASHED_DB)
1438         CF_HASHED_DB($with_hashed_db)
1439 fi
1440
1441 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1442 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1443         CF_STRIP_G_OPT(CFLAGS)
1444         CF_STRIP_G_OPT(CXXFLAGS)
1445 fi
1446
1447 # Just in case, check if the C compiler has a bool type.
1448 CF_BOOL_DECL(cf_cv_cc_bool_type)
1449
1450 # Check for C++ compiler characteristics (and ensure that it's there!)
1451 if test -n "$CXX" ; then
1452         AC_LANG_CPLUSPLUS
1453         CF_STDCPP_LIBRARY
1454         CF_PROG_CC_C_O(CXX)
1455
1456         case $GXX_VERSION in
1457         1*|2.[0-6]*)
1458                 cf_cxx_library=yes
1459                 ;;
1460         *-2.7*|2.7*)
1461                 CF_GPP_LIBRARY
1462                 ;;
1463         *)
1464                 cf_cxx_library=no
1465                 ;;
1466         esac
1467
1468         AC_CHECK_HEADERS(iostream typeinfo)
1469
1470     if test x"$ac_cv_header_iostream" = xyes ; then
1471         AC_MSG_CHECKING(if iostream uses std-namespace)
1472         AC_TRY_COMPILE([
1473 #include <iostream>
1474 using std::endl;
1475 using std::cerr;],[
1476 cerr << "testing" << endl;
1477 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1478         AC_MSG_RESULT($cf_iostream_namespace)
1479         if test "$cf_iostream_namespace" = yes ; then
1480             AC_DEFINE(IOSTREAM_NAMESPACE)
1481         fi
1482     fi
1483
1484         CF_BOOL_DECL
1485         CF_BOOL_SIZE
1486         CF_ETIP_DEFINES
1487         CF_CPP_PARAM_INIT
1488         CF_CPP_STATIC_CAST
1489
1490         CXX_AR='$(AR)'
1491         CXX_ARFLAGS='$(ARFLAGS)'
1492         case $cf_cv_system_name in #(vi
1493         irix*) #(vi
1494             if test "$GXX" != yes ; then
1495                 CXX_AR='$(CXX)'
1496                 CXX_ARFLAGS='-ar -o'
1497             fi
1498             ;;
1499         sco3.2v5*) #(vi
1500             CXXLDFLAGS="-u main"
1501             ;;
1502         solaris2*)
1503             if test "$GXX" != yes ; then
1504                 CXX_AR='$(CXX)'
1505                 CXX_ARFLAGS='-xar -o'
1506             fi
1507             ;;
1508         esac
1509         AC_SUBST(CXXLDFLAGS)
1510         AC_SUBST(CXX_AR)
1511         AC_SUBST(CXX_ARFLAGS)
1512 else
1513         cf_cxx_library=no
1514         cf_cv_builtin_bool=1
1515
1516         # Just because we are not configuring against C++ right now does not
1517         # mean that a user will not want to use C++.  Some distributors disable
1518         # the C++ portion of this configuration as a shortcut (or just to avoid
1519         # compiling the demo in the c++ directory).  So we need a reasonable
1520         # default for the 'bool' type.
1521         #
1522         # Caveat: since the storage of the bool type is not standardized, it
1523         # may change.
1524
1525         if test "$NCURSES_BOOL" != auto ; then
1526                 cf_cv_type_of_bool=$NCURSES_BOOL
1527                 cf_cv_header_stdbool_h=0
1528         else
1529                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1530                         CF_BOOL_SIZE
1531                 else
1532                         AC_MSG_CHECKING(for fallback type of bool)
1533                         case "$host_cpu" in #(vi
1534                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1535                         *)      cf_cv_type_of_bool=int  ;;
1536                         esac
1537                         AC_MSG_RESULT($cf_cv_type_of_bool)
1538                 fi
1539         fi
1540 fi
1541 AC_SUBST(CXXLIBS)
1542
1543 # If the C compiler did not declare bool, and we did not determine that the C++
1544 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1545 # ncurses library use the same type as C++ bool.  Note that this allows one to
1546 # specify the type of bool in a configure-script option and postpone
1547 # integration with the C++ compiler provided that the types are compatible.
1548 USE_CXX_BOOL=1
1549 if test $cf_cv_cc_bool_type = 1
1550 then
1551         # oops: C has a bool.  Unlikely, but C++ could differ.
1552         USE_CXX_BOOL=0
1553 elif test $cf_cv_builtin_bool = 0
1554 then
1555         # C++ has no bool
1556         USE_CXX_BOOL=0
1557 else
1558         # this is the normal case
1559         USE_CXX_BOOL='defined(__cplusplus)'
1560 fi
1561 AC_SUBST(USE_CXX_BOOL)
1562
1563 CF_HELP_MESSAGE(Ada95 Binding Options:)
1564
1565 dnl If the Ada95 source-tree is present, add that to the build unless it will
1566 dnl not work, or was not requested.
1567 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1568
1569 dnl libtool does not know anything about GNAT, though a change made in 1998
1570 dnl provided for it "someday".  Disable the ada subtree if we are using
1571 dnl libtool -TD 20070714
1572         if test "$cf_with_ada" != "no" ; then
1573                 if test "$with_libtool" != "no"; then
1574                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1575                         cf_with_ada=no
1576                 fi
1577         fi
1578
1579 dnl Check for availability of GNU Ada Translator (GNAT).
1580 dnl At the moment we support no other Ada95 compiler.
1581         if test "$cf_with_ada" != "no" ; then
1582                 CF_PROG_GNAT
1583                 if test "$cf_cv_prog_gnat_correct" = yes; then
1584                         CF_ADD_ADAFLAGS(-O3 -gnatpn)
1585
1586                         CF_GNAT_PRAGMA_UNREF
1587
1588                         CF_WITH_ADA_COMPILER
1589
1590                         cf_ada_package=terminal_interface
1591                         AC_SUBST(cf_ada_package)
1592
1593                         CF_WITH_ADA_INCLUDE
1594                         CF_WITH_ADA_OBJECTS
1595                         CF_WITH_ADA_SHAREDLIB
1596                 fi
1597         fi
1598 else
1599         cf_with_ada=no
1600 fi
1601
1602 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1603 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1604 ###
1605 ### ticlib modules may be a separate library, otherwise contained in termlib.
1606 ### termlib modules may be a separate library, otherwise contained in ncurses.
1607 ###
1608 ### The of "+" or " " between the tokens controls the way the script
1609 ### chooses to split module lists into libraries.
1610 ###
1611 ### (see CF_LIB_RULES).
1612 AC_MSG_CHECKING(for library subsets)
1613 LIB_SUBSETS=
1614
1615 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1616         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1617         if test "$with_ticlib" != no ; then
1618                 LIB_SUBSETS="${LIB_SUBSETS} "
1619         else
1620                 LIB_SUBSETS="${LIB_SUBSETS}+"
1621         fi
1622 fi
1623
1624 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1625 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1626
1627 if test "$with_termlib" != no ; then
1628         LIB_SUBSETS="${LIB_SUBSETS} "
1629 else
1630         LIB_SUBSETS="${LIB_SUBSETS}+"
1631 fi
1632
1633 LIB_SUBSETS="${LIB_SUBSETS}base"
1634
1635 # Most term-driver calls are to tinfo, but some like init_pair are to the
1636 # base library (so it resides in base).
1637 if test "$with_term_driver" != no ; then
1638         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1639         case $cf_cv_system_name in #(vi
1640         *mingw32*) #(vi
1641                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1642                 ;;
1643         *) #(vi
1644                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1645                 ;;
1646         esac
1647 fi
1648
1649 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1650 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1651
1652 AC_MSG_RESULT($LIB_SUBSETS)
1653
1654 ### Construct the list of include-directories to be generated
1655 CF_INCLUDE_DIRS
1656 CF_ADA_INCLUDE_DIRS
1657
1658 ### Build up pieces for makefile rules
1659 AC_MSG_CHECKING(default library suffix)
1660 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1661 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1662 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1663
1664 AC_MSG_CHECKING(default library-dependency suffix)
1665 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1666 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1667 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1668
1669 AC_MSG_CHECKING(default object directory)
1670 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1671 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1672 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1673
1674 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1675 if test "$cf_with_cxx" = yes ; then
1676 AC_MSG_CHECKING(c++ library-dependency suffix)
1677 if test "$with_libtool" != "no"; then
1678         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1679 else
1680         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)dnl we normally make a static library
1681 fi
1682 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1683 AC_SUBST(CXX_LIB_SUFFIX)
1684 fi
1685
1686 # do not want -ldl in build except as needed for -lncurses dependency
1687 if test "$with_dlsym" = yes ; then
1688 if test $DFT_LWR_MODEL = shared || \
1689    test $DFT_LWR_MODEL = libtool ; then
1690         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1691 fi
1692 fi
1693 ### Set up low-level terminfo dependencies for makefiles.
1694
1695 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1696 # do not need libdl
1697 TICS_LIST=
1698 if test "$with_dlsym" = yes ; then
1699         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1700 fi
1701
1702 if test "$with_ticlib" != no ; then
1703
1704         if test "$with_ticlib" != yes ; then
1705                 TICS_NAME=$with_ticlib
1706                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1707                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1708                 TICS_LIB_SUFFIX="${with_ticlib}"
1709         else
1710                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1711                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1712                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1713         fi
1714         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1715 else
1716         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1717 fi
1718 AC_SUBST(TICS_ARG_SUFFIX)
1719 AC_SUBST(TICS_DEP_SUFFIX)
1720 AC_SUBST(TICS_LIB_SUFFIX)
1721 AC_SUBST(TICS_ARGS)
1722
1723 if test "$with_termlib" != no ; then
1724
1725         if test "$with_termlib" != yes ; then
1726                 TINFO_NAME=$with_termlib
1727                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1728                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1729                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1730                 TINFO_LIB_SUFFIX="${with_termlib}"
1731         else
1732                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1733                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1734                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1735                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1736         fi
1737
1738         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1739         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1740         if test "$DFT_LWR_MODEL" = "libtool"; then
1741                 TEST_ARGS="${TEST_DEPS}"
1742                 TEST_ARG2="${TEST_DEP2}"
1743                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1744                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1745                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1746         else
1747                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1748                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1749                 TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1750                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1751                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1752         fi
1753 else
1754         # the next lines are needed for linking libtic over libncurses
1755         TINFO_NAME=${LIB_NAME}
1756         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1757         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1758         if test "$with_tic_depends" = yes ; then
1759                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1760         else
1761                 TICS_LIST="$SHLIB_LIST"
1762         fi
1763
1764         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1765 fi
1766
1767 if test "$DFT_LWR_MODEL" = shared ; then
1768         case $cf_cv_system_name in #(vi
1769         cygwin*)
1770                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1771                 TINFO_SUFFIX=.dll
1772                 ;;
1773         esac
1774 fi
1775
1776 AC_SUBST(TINFO_ARG_SUFFIX)
1777 AC_SUBST(TINFO_DEP_SUFFIX)
1778 AC_SUBST(TINFO_LIB_SUFFIX)
1779 AC_SUBST(TINFO_ARGS)
1780
1781 if test "$with_dlsym" = yes ; then
1782         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1783 fi
1784
1785 if test "$DFT_LWR_MODEL" = "libtool"; then
1786     OBJEXT=lo
1787 fi
1788
1789 # needed for Ada95
1790 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1791 AC_SUBST(TINFO_ARGS2)
1792
1793 case $DFT_LWR_MODEL in
1794 normal|debug|profile)
1795         CF_LDFLAGS_STATIC
1796         ;;
1797 esac
1798
1799 AC_MSG_CHECKING(where we will install curses.h)
1800 test "$with_overwrite" = no && \
1801 test "x$includedir" = 'x${prefix}/include' && \
1802         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1803 AC_MSG_RESULT($includedir)
1804
1805 ### Resolve a conflict between normal and wide-curses by forcing applications
1806 ### that will need libutf8 to add it to their configure script.
1807 if test "$with_overwrite" != no ; then
1808 if test "$NCURSES_LIBUTF8" = 1 ; then
1809         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1810         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1811 fi
1812 fi
1813 WITH_OVERWRITE=$with_overwrite
1814
1815 AC_SUBST(WITH_OVERWRITE)
1816 AC_SUBST(TICS_LIST)
1817 AC_SUBST(TINFO_LIST)
1818 AC_SUBST(SHLIB_LIST)
1819
1820 # used to separate tack out of the tree
1821 NCURSES_TREE=
1822 AC_SUBST(NCURSES_TREE)
1823
1824 ### predefined stuff for the test programs
1825 AC_DEFINE(HAVE_SLK_COLOR)
1826
1827 ### Construct the list of subdirectories for which we'll customize makefiles
1828 ### with the appropriate compile-rules.
1829
1830 CF_SRC_MODULES($modules_to_build)
1831
1832 if test "$cf_with_ada" != "no" && test "$cf_cv_prog_gnat_correct" != "no"; then
1833    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1834    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${DFT_ARG_SUFFIX}-config.1:man/MKada_config.in"
1835 fi
1836
1837 CF_DIRS_TO_MAKE
1838
1839 # symbols that differ when compiling Ada95 by itself.
1840 NCURSES_SHLIB2='sh $(top_srcdir)/misc/shlib'
1841 AC_SUBST(NCURSES_SHLIB2)
1842
1843 # values to use as strings
1844 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR')
1845
1846 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1847
1848 ### Now that we're done running tests, add the compiler-warnings, if any
1849 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1850
1851 ### Define substitutions for header files to avoid name-pollution
1852 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1853 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1854 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1855
1856 ################################################################################
1857 test "$use_database" = yes && \
1858 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1859
1860 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1861 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${DFT_ARG_SUFFIX}${cf_cv_abi_version}-config.1:man/MKncu_config.in"
1862
1863 if test x"$enable_pc_files" = xyes ; then \
1864 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1865 MAKE_PC_FILES=
1866 else
1867 MAKE_PC_FILES="#"
1868 fi
1869 AC_SUBST(MAKE_PC_FILES)
1870 AC_SUBST(cross_compiling)
1871
1872 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
1873 if test -n "$FALLBACK_LIST"
1874 then
1875         if test "$TIC_PATH" = unknown
1876         then
1877                 AC_MSG_ERROR(no tic program found for fallbacks)
1878         fi
1879 fi
1880 AC_SUBST(TIC_PATH)
1881
1882 AC_OUTPUT( \
1883         include/MKterm.h.awk \
1884         include/curses.head:include/curses.h.in \
1885         include/ncurses_dll.h \
1886         include/termcap.h \
1887         include/unctrl.h \
1888         $SUB_MAKEFILES \
1889         Makefile,[
1890 CF_PRG_RULES([$srcdir/test/mk-test.awk ECHO_LINK="$ECHO_LINK"], test)
1891 CF_LIB_RULES($SRC_SUBDIRS)
1892
1893 if test "x$cf_with_ada" != xno ; then
1894 if test -z "$USE_OLD_MAKERULES" ; then
1895         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
1896 fi
1897 fi
1898 ],[
1899 ### Special initialization commands, used to pass information from the
1900 ### configuration-run into config.status
1901
1902 AWK="$AWK"
1903 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1904 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1905 ECHO_LINK="$ECHO_LINK"
1906 LDCONFIG="$LDCONFIG"
1907 LIBTOOL_VERSION="$LIBTOOL_VERSION"
1908 LIB_NAME="$LIB_NAME"
1909 LIB_SUBSETS="$LIB_SUBSETS"
1910 LIB_SUFFIX="$LIB_SUFFIX"
1911 LIB_TRACING="$LIB_TRACING"
1912 LN_S="$LN_S"
1913 MAKE_TERMINFO="$MAKE_TERMINFO"
1914 NCURSES_MAJOR="$NCURSES_MAJOR"
1915 NCURSES_MINOR="$NCURSES_MINOR"
1916 NCURSES_OSPEED="$NCURSES_OSPEED"
1917 NCURSES_PATCH="$NCURSES_PATCH"
1918 SRC_SUBDIRS="$SRC_SUBDIRS"
1919 TERMINFO="$TERMINFO"
1920 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1921 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1922 TICS_NAME="$TICS_NAME"
1923 TIC_PATH="$TIC_PATH"
1924 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1925 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1926 TINFO_NAME="$TINFO_NAME"
1927 TINFO_SUFFIX="$TINFO_SUFFIX"
1928 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
1929 WITH_CURSES_H="$with_curses_h"
1930 WITH_ECHO="$with_echo"
1931 WITH_OVERWRITE="$with_overwrite"
1932 cf_LIST_MODELS="$cf_list_models"
1933 cf_cv_abi_version="$cf_cv_abi_version"
1934 cf_cv_do_relink="$cf_cv_do_relink"
1935 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1936 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1937 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1938 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1939 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1940 cf_cv_rel_version="$cf_cv_rel_version"
1941 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1942 cf_cv_shared_soname='$cf_cv_shared_soname'
1943 cf_cv_shlib_version="$cf_cv_shlib_version"
1944 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1945 cf_cv_system_name="$cf_cv_system_name"
1946 cf_with_ada="$cf_with_ada"
1947 cf_with_cxx_binding="$cf_with_cxx_binding"
1948 cf_with_manpages="$cf_with_manpages"
1949 host="$host"
1950 target="$target"
1951
1952 ],cat)dnl
1953 ${MAKE-make} preinstall