configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2017,2018 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.664 2018/08/18 20:27:17 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See https://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.52.20170501)
  38 AC_REVISION($Revision: 1.664 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44 CF_VERSION_INFO(NCURSES,ncurses)
  45
  46 CF_WITH_REL_VERSION(NCURSES)
  47 CF_NCURSES_WITH_ABI_VERSION
  48
  49 CF_WITH_SYSTYPE
  50
  51 ###     Save the given $CFLAGS to allow user-override.
  52 cf_user_CFLAGS="$CFLAGS"
  53
  54 ###     Default install-location
  55 CF_CFG_DEFAULTS
  56 ### Defaults for ncurses ABI
  57 CF_ABI_DEFAULTS
  58
  59 ###     Checks for programs.
  60 AC_ARG_WITH(ada,
  61         [  --without-ada           suppress check for Ada95, don't build demo],
  62         [cf_with_ada=$withval],
  63         [cf_with_ada=yes])
  64 if test "x$cf_with_ada" = xyes
  65 then
  66         cf_PROG_CC="gnatgcc gcc cc"
  67 else
  68         cf_PROG_CC="gcc cc"
  69 fi
  70
  71 CF_PROG_CC($cf_PROG_CC)
  72
  73 AC_PROG_CPP
  74 AC_PROG_GCC_TRADITIONAL
  75 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
  76 CF_PROG_LDCONFIG
  77
  78 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  79 dnl                             configure script by not letting us test if C++
  80 dnl                             is present, making this option necessary.
  81 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  82 AC_ARG_WITH(cxx,
  83         [  --without-cxx           do not adjust ncurses bool to match C++],
  84         [cf_with_cxx=$withval],
  85         [cf_with_cxx=yes])
  86 AC_MSG_RESULT($cf_with_cxx)
  87 if test "X$cf_with_cxx" = Xno ; then
  88         CXX=""
  89         GXX=""
  90 else
  91         # with autoconf 2.13, we can change the error to a warning:
  92         pushdef([AC_MSG_ERROR],
  93                 [AC_MSG_RESULT(no)
  94                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  95                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  96         AC_PROG_CXX
  97         popdef([AC_MSG_ERROR])dnl
  98
  99         AC_LANG_PUSH(C++)
 100         if test "x$cf_with_cxx" != xno
 101         then
 102                 # Several of the C++ configurations do not work, particularly when
 103                 # cross-compiling (20140913 -TD)
 104                 AC_MSG_CHECKING(if $CXX works)
 105
 106                 save_CPPFLAGS="$CPPFLAGS"
 107                 eval cf_includedir=${includedir}
 108                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
 109                 AC_TRY_COMPILE([
 110 #include <stdlib.h>
 111 #include <stdio.h>
 112 ],
 113                 [
 114                 printf("Hello world!\n")
 115                 ],
 116                 [cf_cxx_works=yes],
 117                 [cf_cxx_works=no])
 118                 CPPFLAGS="$save_CPPFLAGS"
 119
 120                 AC_MSG_RESULT($cf_cxx_works)
 121                 if test "x$cf_cxx_works" = xno
 122                 then
 123                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
 124                         cf_with_cxx=no; CXX=""; GXX="";
 125                 fi
 126         fi
 127         AC_LANG_POP
 128
 129         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
 130         if test "$CXX" = "g++" ; then
 131                 AC_PATH_PROG(CXX,g++)
 132         fi
 133         case "x$CXX" in
 134         (x|xg++)
 135                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
 136                 cf_with_cxx=no; CXX=""; GXX="";
 137                 ;;
 138         esac
 139 fi
 140
 141 CF_GXX_VERSION
 142 case $GXX_VERSION in
 143 (1*|2.[[0-6]]*)
 144         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 145         # cf_cxx_library=no
 146         AC_MSG_WARN(templates do not work)
 147         ;;
 148 esac
 149
 150 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 151 AC_ARG_WITH(cxx-binding,
 152         [  --without-cxx-binding   do not build C++ binding and demo],
 153         [cf_with_cxx_binding=$withval],
 154         [cf_with_cxx_binding=$cf_with_cxx])
 155 AC_MSG_RESULT($cf_with_cxx_binding)
 156
 157 AC_MSG_CHECKING(if you want to build with Ada95)
 158 AC_MSG_RESULT($cf_with_ada)
 159
 160 AC_MSG_CHECKING(if you want to install terminal database)
 161 AC_ARG_ENABLE(db-install,
 162         [  --disable-db-install    suppress install of terminal database],
 163         [cf_with_db_install=$enableval],
 164         [cf_with_db_install=yes])
 165 AC_MSG_RESULT($cf_with_db_install)
 166
 167 AC_MSG_CHECKING(if you want to install manpages)
 168 AC_ARG_WITH(manpages,
 169         [  --without-manpages      suppress install of manpages],
 170         [cf_with_manpages=$withval],
 171         [cf_with_manpages=yes])
 172 AC_MSG_RESULT($cf_with_manpages)
 173
 174 AC_MSG_CHECKING(if you want to build programs such as tic)
 175 AC_ARG_WITH(progs,
 176         [  --without-progs         suppress build/install with programs (e.g., tic)],
 177         [cf_with_progs=$withval],
 178         [cf_with_progs=yes])
 179 AC_MSG_RESULT($cf_with_progs)
 180
 181 if test -f $srcdir/tack/tack.h; then
 182         if test "x$cross_compiling" = xyes ; then
 183                 CF_VERBOSE(ignoring tack because we are cross-compiling)
 184                 cf_with_tack=no
 185         else
 186                 AC_MSG_CHECKING(if you want to build the tack program)
 187                 AC_ARG_WITH(tack,
 188                         [  --without-tack          suppress build/install with tack program],
 189                         [cf_with_tack=$withval],
 190                         [cf_with_tack=$cf_with_progs])
 191                 AC_MSG_RESULT($cf_with_tack)
 192         fi
 193 else
 194         cf_with_tack=no
 195 fi
 196
 197 AC_MSG_CHECKING(if you want to build test-programs)
 198 AC_ARG_WITH(tests,
 199         [  --without-tests         suppress build/install with test-programs],
 200         [cf_with_tests=$withval],
 201         [cf_with_tests=yes])
 202 AC_MSG_RESULT($cf_with_tests)
 203
 204 AC_MSG_CHECKING(if you wish to install curses.h)
 205 AC_ARG_WITH(curses-h,
 206         [  --without-curses-h      install curses.h as ncurses.h only],
 207         [with_curses_h=$withval],
 208         [with_curses_h=yes])
 209 AC_MSG_RESULT($with_curses_h)
 210
 211 modules_to_build="ncurses"
 212 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
 213 test "X$cf_with_tack"  != Xno && modules_to_build="$modules_to_build tack"
 214 modules_to_build="$modules_to_build panel menu form"
 215
 216 AC_ARG_PROGRAM
 217
 218 CF_PROG_AWK
 219 CF_PROG_EGREP
 220 AC_PROG_INSTALL
 221 CF_PROG_LINT
 222 CF_PROG_LN_S
 223
 224 AC_SYS_LONG_FILE_NAMES
 225
 226 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
 227 # of package conflict.
 228 cf_config_suffix=
 229 AC_ARG_WITH(config-suffix,
 230         [  --with-config-suffix=X  suffixes ncursesXX-config file],
 231         [case "x$withval" in
 232         (xyes|xno)
 233                 AC_MSG_WARN(expected a value for config-suffix option)
 234                 ;;
 235         (*)     cf_config_suffix="$withval"
 236                 ;;
 237         esac])
 238 AC_SUBST(cf_config_suffix)
 239
 240 # If we find pkg-config, check if we should install the ".pc" files.
 241 CF_PKG_CONFIG
 242 CF_WITH_PKG_CONFIG_LIBDIR
 243 CF_ENABLE_PC_FILES
 244 if test -z "$MAKE_PC_FILES"
 245 then
 246         AC_MSG_CHECKING(for suffix to add to pc-files)
 247 AC_ARG_WITH(pc-suffix,
 248         [  --with-pc-suffix        suffixes pc-files],
 249         [case "x$withval" in
 250         (xyes|xno)
 251                 PC_MODULE_SUFFIX=
 252                 ;;
 253         (*)     PC_MODULE_SUFFIX="$withval"
 254                 ;;
 255         esac])
 256         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
 257         AC_MSG_RESULT($PC_MODULE_SUFFIX)
 258         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
 259         AC_SUBST(PC_MODULE_SUFFIX)
 260 fi
 261
 262 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 263 AC_ARG_ENABLE(mixed-case,
 264         [  --enable-mixed-case     tic should assume mixed-case filenames],
 265         [enable_mixedcase=$enableval],
 266         [enable_mixedcase=auto])
 267 AC_MSG_RESULT($enable_mixedcase)
 268 if test "$enable_mixedcase" = "auto" ; then
 269         CF_MIXEDCASE_FILENAMES
 270 else
 271         cf_cv_mixedcase=$enable_mixedcase
 272         if test "x$enable_mixedcase" = "xyes" ; then
 273                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
 274         fi
 275 fi
 276
 277 # do this after mixed-case option (tags/TAGS is not as important as tic).
 278 AC_PROG_MAKE_SET
 279 CF_MAKE_TAGS
 280 CF_MAKEFLAGS
 281
 282 dnl These are standard among *NIX systems, but not when cross-compiling
 283 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 284 AC_CHECK_TOOL(LD, ld, ld)
 285 AC_CHECK_TOOL(AR, ar, ar)
 286 AC_CHECK_TOOL(NM, nm, nm)
 287 CF_AR_FLAGS
 288
 289 dnl Special option for use by system-builders: the install-prefix is used to
 290 dnl adjust the location into which the actual install is done, so that an
 291 dnl archive can be built without modifying the host system's configuration.
 292 AC_MSG_CHECKING(if you have specified an install-prefix)
 293 AC_ARG_WITH(install-prefix,
 294         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 295         [case "x$withval" in
 296         (xyes|xno)
 297                 ;;
 298         (*)     DESTDIR="$withval"
 299                 ;;
 300         esac])
 301 AC_MSG_RESULT($DESTDIR)
 302 AC_SUBST(DESTDIR)
 303
 304 ###############################################################################
 305 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 306 # If we're cross-compiling, allow the user to override the tools and their
 307 # options.  The configure script is oriented toward identifying the host
 308 # compiler, etc., but we need a build compiler to generate parts of the source.
 309 CF_BUILD_CC
 310
 311 ###############################################################################
 312 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 313
 314 ### Options to allow the user to specify the set of libraries which are used.
 315 ### Use "--without-normal --with-shared" to allow the default model to be
 316 ### shared, for example.
 317 cf_list_models=""
 318 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 319
 320 CF_WITH_LIBTOOL
 321 if test "$with_libtool" != "no" ; then
 322
 323 cf_list_models="$cf_list_models libtool"
 324
 325 else
 326
 327 AC_MSG_CHECKING(if you want to build shared libraries)
 328 AC_ARG_WITH(shared,
 329         [  --with-shared           generate shared-libraries],
 330         [with_shared=$withval],
 331         [with_shared=no])
 332 AC_MSG_RESULT($with_shared)
 333 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
 334
 335 AC_MSG_CHECKING(if you want to build static libraries)
 336 AC_ARG_WITH(normal,
 337         [  --with-normal           generate normal-libraries (default)],
 338         [with_normal=$withval],
 339         [with_normal=yes])
 340 AC_MSG_RESULT($with_normal)
 341 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
 342
 343 AC_MSG_CHECKING(if you want to build debug libraries)
 344 AC_ARG_WITH(debug,
 345         [  --with-debug            generate debug-libraries (default)],
 346         [with_debug=$withval],
 347         [with_debug=yes])
 348 AC_MSG_RESULT($with_debug)
 349 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
 350
 351 AC_MSG_CHECKING(if you want to build profiling libraries)
 352 AC_ARG_WITH(profile,
 353         [  --with-profile          generate profile-libraries],
 354         [with_profile=$withval],
 355         [with_profile=no])
 356 AC_MSG_RESULT($with_profile)
 357 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
 358
 359 fi
 360
 361 if test "X$cf_with_cxx_binding" != Xno; then
 362 if test "x$with_shared" = "xyes"; then
 363 AC_MSG_CHECKING(if you want to build C++ shared libraries)
 364 AC_ARG_WITH(cxx-shared,
 365         [  --with-cxx-shared       generate C++ shared-libraries],
 366         [with_shared_cxx=$withval],
 367         [with_shared_cxx=no])
 368 AC_MSG_RESULT($with_shared_cxx)
 369 fi
 370 fi
 371
 372 ###############################################################################
 373
 374 AC_MSG_CHECKING(for specified models)
 375 test -z "$cf_list_models" && cf_list_models=normal
 376 dnl If we use libtool to generate libraries, then it must be the only
 377 dnl specified model.
 378 test "$with_libtool" != "no" && cf_list_models=libtool
 379 AC_MSG_RESULT($cf_list_models)
 380
 381 ### Use the first model as the default, and save its suffix for use in building
 382 ### up test-applications.
 383 AC_MSG_CHECKING(for default model)
 384 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 385 AC_MSG_RESULT($DFT_LWR_MODEL)
 386
 387 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 388
 389 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 390 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 391
 392 TICS_NAME=tic
 393 AC_SUBST(TICS_NAME)
 394
 395 TINFO_NAME=tinfo
 396 AC_SUBST(TINFO_NAME)
 397
 398 LIB_NAME=ncurses
 399 AC_SUBST(LIB_NAME)
 400
 401 LIB_DIR=../lib
 402 LIB_2ND=../../lib
 403
 404 CF_WITH_LIB_PREFIX(cf_prefix)
 405
 406 LIB_SUFFIX=
 407 AC_SUBST(LIB_SUFFIX)
 408 CF_PATHSEP
 409
 410 ###############################################################################
 411
 412 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 413 AC_ARG_WITH(termlib,
 414         [  --with-termlib          generate separate terminfo library],
 415         [with_termlib=$withval],
 416         [with_termlib=no])
 417 AC_MSG_RESULT($with_termlib)
 418
 419 AC_MSG_CHECKING(if you want to build a separate tic library)
 420 AC_ARG_WITH(ticlib,
 421         [  --with-ticlib           generate separate tic library],
 422         [with_ticlib=$withval],
 423         [with_ticlib=no])
 424 AC_MSG_RESULT($with_ticlib)
 425
 426 dnl Not all ports of gcc support the -g option
 427
 428 if test X"$CC_G_OPT" = X"" ; then
 429         CC_G_OPT='-g'
 430         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
 431 fi
 432 AC_SUBST(CC_G_OPT)
 433
 434 if test X"$CXX_G_OPT" = X"" ; then
 435         CXX_G_OPT='-g'
 436         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
 437 fi
 438 AC_SUBST(CXX_G_OPT)
 439
 440 AC_MSG_CHECKING(for default loader flags)
 441 case $DFT_LWR_MODEL in
 442 (libtool) LD_MODEL=''   ;;
 443 (normal)  LD_MODEL=''   ;;
 444 (debug)   LD_MODEL=$CC_G_OPT ;;
 445 (profile) LD_MODEL='-pg';;
 446 (shared)  LD_MODEL=''   ;;
 447 esac
 448 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 449 AC_MSG_RESULT($LD_MODEL)
 450
 451 case $DFT_LWR_MODEL in
 452 (shared)
 453 CF_ENABLE_RPATH
 454 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 455 AC_ARG_ENABLE(relink,
 456 [  --disable-relink        relink shared libraries during install],
 457 [cf_cv_do_relink=$enableval],
 458 [cf_cv_do_relink=yes])
 459 AC_MSG_RESULT($cf_cv_do_relink)
 460         ;;
 461 esac
 462
 463 # we will build libraries one-level down.
 464 rel_builddir=..
 465 CF_SHARED_OPTS
 466 for model in $cf_list_models; do
 467         case $model in
 468         (libtool)
 469                 CF_WITH_LIBTOOL_OPTS
 470                 CF_WITH_EXPORT_SYMS
 471                 ;;
 472         (shared)
 473                 if test "$CC_SHARED_OPTS" = "unknown"; then
 474                         AC_ERROR(Shared libraries are not supported in this version)
 475                 fi
 476                 # workaround for inept transition to PIE vs PIC...
 477                 AC_MSG_CHECKING(if current CFLAGS link properly)
 478                 AC_TRY_LINK(
 479                         [#include <stdio.h>],
 480                         [printf("Hello work\n");],
 481                         [cf_cflags_work=yes],
 482                         [cf_cflags_work=no])
 483                 AC_MSG_RESULT($cf_cflags_work)
 484                 if test "$cf_cflags_work" = no
 485                 then
 486                         CF_VERBOSE(try to work around by appending shared-options)
 487                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
 488                 fi
 489                 CF_WITH_VERSIONED_SYMS
 490                 ;;
 491         esac
 492 done
 493
 494 ### Checks for special libraries, must be done up-front.
 495 SHLIB_LIST=""
 496 CF_WITH_GPM
 497 if test "$with_gpm" != no ; then
 498         AC_MSG_CHECKING(if you want to load GPM dynamically)
 499         AC_ARG_WITH(dlsym,
 500                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 501                 [with_dlsym=$withval],
 502                 [with_dlsym=yes])
 503         AC_MSG_RESULT($with_dlsym)
 504         if test "x$with_dlsym" = xyes ; then
 505                 CF_FUNC_DLSYM
 506                 if test "x$with_gpm" != xyes ; then
 507                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 508                         cf_cv_gpm_soname="$with_gpm"
 509                 else
 510                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 511                 fi
 512                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
 513                 SHLIB_LIST="-ldl $SHLIB_LIST"
 514                 CF_ADD_LIB(dl,PRIVATE_LIBS)
 515         else
 516                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 517                 CF_ADD_LIB(gpm,TEST_LIBS)
 518                 CF_ADD_LIB(gpm,PRIVATE_LIBS)
 519         fi
 520         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
 521         CF_CHECK_GPM_WGETCH
 522 fi
 523
 524 CF_WITH_PCRE2
 525 CF_WITH_SYSMOUSE
 526
 527 # pretend that ncurses==ncursesw==ncursest
 528 AC_MSG_CHECKING(if you want to disable library suffixes)
 529 CF_ARG_DISABLE(lib-suffixes,
 530         [  --disable-lib-suffixes  disable library suffixes],
 531         [disable_lib_suffixes=yes],
 532         [disable_lib_suffixes=no],
 533         no)
 534 AC_MSG_RESULT($disable_lib_suffixes)
 535
 536 ### If we're building with rpath, try to link non-standard libs that way too.
 537 if test "$DFT_LWR_MODEL" = "shared" && test "x$cf_cv_enable_rpath" != xno; then
 538         CF_DISABLE_RPATH_HACK
 539 fi
 540
 541 ###############################################################################
 542 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 543
 544 ###     use option --with-extra-suffix to append suffix to headers and libraries
 545 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
 546 EXTRA_SUFFIX=
 547 AC_ARG_WITH(extra-suffix,
 548         [  --with-extra-suffix=X   append extra suffix to header/library paths],
 549         [case x$withval in
 550         (no)
 551                 ;;
 552         (xyes|x)
 553                 EXTRA_SUFFIX=$cf_cv_abi_version
 554                 ;;
 555         (*)
 556                 EXTRA_SUFFIX=$withval
 557                 ;;
 558         esac
 559         ])
 560 AC_MSG_RESULT($EXTRA_SUFFIX)
 561 AC_SUBST(EXTRA_SUFFIX)
 562
 563 ###     use option --disable-overwrite to leave out the link to -lcurses
 564 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 565 AC_ARG_ENABLE(overwrite,
 566         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
 567         [with_overwrite=$enableval],
 568         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 569 AC_MSG_RESULT($with_overwrite)
 570
 571 AC_MSG_CHECKING(if external terminfo-database is used)
 572 AC_ARG_ENABLE(database,
 573         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 574         [use_database=$enableval],
 575         [use_database=yes])
 576 AC_MSG_RESULT($use_database)
 577
 578 case $host_os in
 579 (os2*)
 580         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 581         ;;
 582 (*)
 583         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 584         ;;
 585 esac
 586 AC_SUBST(TERMINFO_SRC)
 587
 588 NCURSES_USE_DATABASE=0
 589 if test "$use_database" != no ; then
 590         NCURSES_USE_DATABASE=1
 591
 592         AC_MSG_CHECKING(which terminfo source-file will be installed)
 593         AC_ARG_WITH(database,
 594                 [  --with-database=XXX     specify terminfo source to install],
 595                 [TERMINFO_SRC=$withval])
 596         AC_MSG_RESULT($TERMINFO_SRC)
 597
 598         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 599         AC_ARG_WITH(hashed-db,
 600                 [  --with-hashed-db        specify hashed-database library],,
 601                 [with_hashed_db=no])
 602         AC_MSG_RESULT($with_hashed_db)
 603 else
 604         with_hashed_db=no
 605 fi
 606 AC_SUBST(NCURSES_USE_DATABASE)
 607
 608 AC_MSG_CHECKING(for list of fallback descriptions)
 609 AC_ARG_WITH(fallbacks,
 610         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 611         [with_fallback=$withval],
 612         [with_fallback=])
 613 AC_MSG_RESULT($with_fallback)
 614 FALLBACK_LIST=`test "$with_fallback" != no && echo "$with_fallback" | sed -e 's/,/ /g'`
 615 AC_SUBST(FALLBACK_LIST)
 616
 617 AC_MSG_CHECKING(if you want modern xterm or antique)
 618 AC_ARG_WITH(xterm-new,
 619         [  --without-xterm-new     specify if xterm terminfo should be old version],
 620         [with_xterm_new=$withval],
 621         [with_xterm_new=yes])
 622 case $with_xterm_new in
 623 (no) with_xterm_new=xterm-old;;
 624 (*)      with_xterm_new=xterm-new;;
 625 esac
 626 AC_MSG_RESULT($with_xterm_new)
 627 WHICH_XTERM=$with_xterm_new
 628 AC_SUBST(WHICH_XTERM)
 629
 630 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 631 AC_ARG_WITH(xterm-kbs,
 632         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
 633         [with_xterm_kbs=$withval],
 634         [with_xterm_kbs=BS])
 635 case x$with_xterm_kbs in
 636 (xyes|xno|xBS|xbs|x8)
 637         with_xterm_kbs=BS
 638         ;;
 639 (xDEL|xdel|x127)
 640         with_xterm_kbs=DEL
 641         ;;
 642 (*)
 643         with_xterm_kbs=$withval
 644         ;;
 645 esac
 646 AC_MSG_RESULT($with_xterm_kbs)
 647 XTERM_KBS=$with_xterm_kbs
 648 AC_SUBST(XTERM_KBS)
 649
 650 MAKE_TERMINFO=
 651 if test "$use_database" = no ; then
 652         TERMINFO="${datadir}/terminfo"
 653         MAKE_TERMINFO="#"
 654 else
 655
 656 AC_MSG_CHECKING(for list of terminfo directories)
 657 CF_WITH_PATHLIST(terminfo-dirs,
 658         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 659         TERMINFO_DIRS,
 660         DATADIR/terminfo,
 661         ${datadir}/terminfo)
 662 AC_MSG_RESULT($TERMINFO_DIRS)
 663 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
 664
 665 AC_MSG_CHECKING(for default terminfo directory)
 666 CF_WITH_PATH(default-terminfo-dir,
 667         [  --with-default-terminfo-dir=DIR default terminfo directory],
 668         TERMINFO,
 669         DATADIR/terminfo,
 670         ${datadir}/terminfo)
 671 AC_MSG_RESULT($TERMINFO)
 672 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
 673
 674 fi
 675
 676 AC_SUBST(TERMINFO)
 677 AC_SUBST(MAKE_TERMINFO)
 678
 679 ###     use option --disable-big-core to make tic run on small machines
 680 ###     We need 4Mb, check if we can allocate 50% more than that.
 681 AC_MSG_CHECKING(if big-core option selected)
 682 AC_ARG_ENABLE(big-core,
 683         [  --disable-big-core      assume machine has little memory],
 684         [with_big_core=$enableval],
 685         [AC_TRY_RUN([
 686 #include <stdlib.h>
 687 #include <string.h>
 688 int main() {
 689         unsigned long n = 6000000L;
 690         char *s = malloc(n);
 691         if (s != 0)
 692                 s[0] = s[n-1] = 0;
 693         ${cf_cv_main_return:-return}(s == 0);
 694 }],
 695         [with_big_core=yes],
 696         [with_big_core=no],
 697         [with_big_core=no])])
 698 AC_MSG_RESULT($with_big_core)
 699 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
 700
 701 ### ISO C only guarantees 512-char strings, we have tables which load faster
 702 ### when constructed using "big" strings.  More than the C compiler, the awk
 703 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 704 AC_MSG_CHECKING(if big-strings option selected)
 705 AC_ARG_ENABLE(big-strings,
 706         [  --disable-big-strings   assume compiler has only standard-size strings],
 707         [with_big_strings=$enableval],
 708         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 709 AC_MSG_RESULT($with_big_strings)
 710
 711 USE_BIG_STRINGS=0
 712 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
 713 AC_SUBST(USE_BIG_STRINGS)
 714
 715 ###     use option --enable-termcap to compile in the termcap fallback support
 716 AC_MSG_CHECKING(if you want termcap-fallback support)
 717 AC_ARG_ENABLE(termcap,
 718         [  --enable-termcap        compile in termcap fallback support],
 719         [with_termcap=$enableval],
 720         [with_termcap=no])
 721 AC_MSG_RESULT($with_termcap)
 722
 723 NCURSES_USE_TERMCAP=0
 724 if test "x$with_termcap" != "xyes" ; then
 725         if test "$use_database" = no ; then
 726                 if test -z "$with_fallback" ; then
 727                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 728                 fi
 729         fi
 730         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
 731 else
 732
 733         if test "$with_ticlib" != no ; then
 734                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 735         fi
 736
 737         NCURSES_USE_TERMCAP=1
 738         AC_MSG_CHECKING(for list of termcap files)
 739         CF_WITH_PATHLIST(termpath,
 740                 [  --with-termpath=XXX     specify list of termcap files],
 741                 TERMPATH,
 742                 /etc/termcap:/usr/share/misc/termcap)
 743         AC_MSG_RESULT($TERMPATH)
 744         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
 745
 746         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 747         AC_MSG_CHECKING(if fast termcap-loader is needed)
 748         AC_ARG_ENABLE(getcap,
 749                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 750                 [with_getcap=$enableval],
 751                 [with_getcap=no])
 752         AC_MSG_RESULT($with_getcap)
 753         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
 754
 755         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 756         AC_ARG_ENABLE(getcap-cache,
 757                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 758                 [with_getcap_cache=$enableval],
 759                 [with_getcap_cache=no])
 760         AC_MSG_RESULT($with_getcap_cache)
 761         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
 762
 763 fi
 764 AC_SUBST(NCURSES_USE_TERMCAP)
 765
 766 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 767 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 768 AC_ARG_ENABLE(home-terminfo,
 769         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 770         [with_home_terminfo=$enableval],
 771         [with_home_terminfo=yes])
 772 AC_MSG_RESULT($with_home_terminfo)
 773 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
 774
 775 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 776 AC_ARG_ENABLE(root-environ,
 777         [  --disable-root-environ  restrict environment when running as root],
 778         [with_root_environ=$enableval],
 779         [with_root_environ=yes])
 780 AC_MSG_RESULT($with_root_environ)
 781 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
 782
 783 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 784 ###   to reduce storage requirements for the terminfo database.
 785 CF_LINK_FUNCS
 786
 787 with_links=no
 788 with_symlinks=no
 789
 790 # soft links (symbolic links) are useful for some systems where hard links do
 791 # not work, or to make it simpler to copy terminfo trees around.
 792 if test "x$ac_cv_func_symlink" = xyes ; then
 793         AC_MSG_CHECKING(if tic should use symbolic links)
 794         AC_ARG_ENABLE(symlinks,
 795         [  --enable-symlinks       make tic use symbolic links not hard links],
 796         [with_symlinks=$enableval],
 797         [with_symlinks=no])
 798         AC_MSG_RESULT($with_symlinks)
 799 fi
 800
 801 # If we have hard links and did not choose to use soft links instead, there is
 802 # no reason to make this choice optional - use the hard links.
 803 if test "$with_symlinks" = no ; then
 804         AC_MSG_CHECKING(if tic should use hard links)
 805         if test "x$ac_cv_func_link" = xyes ; then
 806                 with_links=yes
 807         else
 808                 with_links=no
 809         fi
 810         AC_MSG_RESULT($with_links)
 811 fi
 812
 813 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
 814 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
 815
 816 ###   use option --enable-broken-linker to force on use of broken-linker support
 817 AC_MSG_CHECKING(if you want broken-linker support code)
 818 AC_ARG_ENABLE(broken_linker,
 819         [  --enable-broken_linker  compile with broken-linker support code],
 820         [with_broken_linker=$enableval],
 821         [with_broken_linker=${BROKEN_LINKER:-no}])
 822 AC_MSG_RESULT($with_broken_linker)
 823
 824 BROKEN_LINKER=0
 825 if test "x$with_broken_linker" = xyes ; then
 826         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
 827         BROKEN_LINKER=1
 828 elif test "$DFT_LWR_MODEL" = shared ; then
 829         case $cf_cv_system_name in
 830         (cygwin*)
 831                 AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
 832                 BROKEN_LINKER=1
 833                 CF_VERBOSE(cygwin linker is broken anyway)
 834                 ;;
 835         esac
 836 fi
 837 AC_SUBST(BROKEN_LINKER)
 838
 839 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 840 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 841 AC_ARG_ENABLE(bsdpad,
 842         [  --enable-bsdpad         recognize BSD-style prefix padding],
 843         [with_bsdpad=$enableval],
 844         [with_bsdpad=no])
 845 AC_MSG_RESULT($with_bsdpad)
 846 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
 847
 848 ###   use option --enable-widec to turn on use of wide-character support
 849 NCURSES_CH_T=chtype
 850 NCURSES_LIBUTF8=0
 851
 852 NEED_WCHAR_H=0
 853 NCURSES_MBSTATE_T=0
 854 NCURSES_WCHAR_T=0
 855 NCURSES_WINT_T=0
 856
 857 # Check to define _XOPEN_SOURCE "automatically"
 858 CPPFLAGS_before_XOPEN="$CPPFLAGS"
 859 CF_XOPEN_SOURCE(600)
 860 CPPFLAGS_after_XOPEN="$CPPFLAGS"
 861
 862 # Work around breakage on OS X
 863 CF_SIGWINCH
 864
 865 # Checks for CODESET support.
 866 AM_LANGINFO_CODESET
 867
 868 # use these variables to work around a defect in gcc's fixincludes.
 869 NCURSES_OK_WCHAR_T=
 870 NCURSES_OK_WINT_T=
 871
 872 AC_MSG_CHECKING(if you want wide-character code)
 873 AC_ARG_ENABLE(widec,
 874         [  --enable-widec          compile with wide-char/UTF-8 code],
 875         [with_widec=$enableval],
 876         [with_widec=no])
 877 AC_MSG_RESULT($with_widec)
 878
 879 NCURSES_WCWIDTH_GRAPHICS=1
 880 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
 881
 882 if test "x$with_widec" = xyes ; then
 883         if test "x$disable_lib_suffixes" = xno ; then
 884                 LIB_SUFFIX="w${LIB_SUFFIX}"
 885         fi
 886         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
 887         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
 888
 889         CF_CHECK_WCHAR_H
 890         CF_CHECK_WCWIDTH_GRAPHICS
 891         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
 892
 893         # with_overwrite=no
 894         NCURSES_CH_T=cchar_t
 895         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 896         if test "x$ac_cv_func_putwc" != xyes ; then
 897                 CF_UTF8_LIB
 898                 if test "$cf_cv_utf8_lib" != no ; then
 899                         NCURSES_LIBUTF8=1
 900                 fi
 901         fi
 902         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 903         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 904         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 905
 906         if test "$NCURSES_MBSTATE_T" != 0; then
 907                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
 908         fi
 909 fi
 910 AC_SUBST(NCURSES_CH_T)
 911 AC_SUBST(NCURSES_LIBUTF8)
 912
 913 AC_SUBST(NEED_WCHAR_H)
 914 AC_SUBST(NCURSES_MBSTATE_T)
 915 AC_SUBST(NCURSES_WCHAR_T)
 916 AC_SUBST(NCURSES_WINT_T)
 917
 918 AC_SUBST(NCURSES_OK_WCHAR_T)
 919 AC_SUBST(NCURSES_OK_WINT_T)
 920
 921 ###   use option --disable-lp64 to allow long chtype
 922 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 923 AC_ARG_ENABLE(lp64,
 924         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 925         [with_lp64=$enableval],
 926         [with_lp64=$cf_dft_with_lp64])
 927 AC_MSG_RESULT($with_lp64)
 928
 929 if test "x$with_lp64" = xyes ; then
 930         cf_cv_enable_lp64=1
 931 else
 932         cf_cv_enable_lp64=0
 933 fi
 934 AC_SUBST(cf_cv_enable_lp64)
 935
 936 CF_LARGEFILE
 937
 938 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 939 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 940 AC_ARG_ENABLE(tparm-varargs,
 941         [  --disable-tparm-varargs compile tparm() without varargs interface],
 942         [with_tparm_varargs=$enableval],
 943         [with_tparm_varargs=yes])
 944 AC_MSG_RESULT($with_tparm_varargs)
 945 NCURSES_TPARM_VARARGS=0
 946 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
 947 AC_SUBST(NCURSES_TPARM_VARARGS)
 948
 949 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 950 if test "$with_ticlib" != no ; then
 951 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 952 AC_ARG_ENABLE(tic-depends,
 953         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 954         [with_tic_depends=$enableval],
 955         [with_tic_depends=yes])
 956 AC_MSG_RESULT($with_tic_depends)
 957 else
 958         with_tic_depends=no
 959 fi
 960
 961 ###   use option --disable-wattr-macros to suppress wattr* macros from curses.h
 962 AC_MSG_CHECKING(if you want to suppress wattr* macros to help with ncurses5/ncurses6 transition)
 963 AC_ARG_ENABLE(wattr-macros,
 964         [  --disable-wattr-macros  suppress wattr* macros to help with ncurses5/ncurses6 transition],
 965         [with_wattr_macros=$enableval],
 966         [with_wattr_macros=yes])
 967 if [[ "x$with_wattr_macros" != xyes ]]; then
 968         NCURSES_WATTR_MACROS=0
 969         AC_MSG_RESULT(yes)
 970 else
 971         NCURSES_WATTR_MACROS=1
 972         AC_MSG_RESULT(no)
 973 fi
 974 AC_SUBST(NCURSES_WATTR_MACROS)
 975
 976 CF_WITH_X11_RGB
 977
 978 ###   use option --with-bool to override bool's type
 979 AC_MSG_CHECKING(for type of bool)
 980 AC_ARG_WITH(bool,
 981         [  --with-bool=TYPE        override fallback type of bool variable],
 982         [NCURSES_BOOL="$withval"],
 983         [NCURSES_BOOL=auto])
 984 AC_MSG_RESULT($NCURSES_BOOL)
 985 AC_SUBST(NCURSES_BOOL)
 986
 987 AC_MSG_CHECKING(for alternate terminal capabilities file)
 988 AC_ARG_WITH(caps,
 989         [  --with-caps=alt         compile with alternate Caps file],
 990         [TERMINFO_CAPS=Caps.$withval],
 991         [TERMINFO_CAPS=Caps])
 992 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 993 AC_MSG_RESULT($TERMINFO_CAPS)
 994 AC_SUBST(TERMINFO_CAPS)
 995
 996 ###   use option --with-chtype to override chtype's type
 997 AC_MSG_CHECKING(for type of chtype)
 998 AC_ARG_WITH(chtype,
 999         [  --with-chtype=TYPE      override type of chtype],
1000         [NCURSES_CHTYPE="$withval"],
1001         [NCURSES_CHTYPE=$cf_dft_chtype])
1002 AC_MSG_RESULT($NCURSES_CHTYPE)
1003
1004 ###   use option --with-ospeed to override ospeed's type
1005 AC_MSG_CHECKING(for type of ospeed)
1006 AC_ARG_WITH(ospeed,
1007         [  --with-ospeed=TYPE      override type of ospeed variable],
1008         [NCURSES_OSPEED="$withval"],
1009         [NCURSES_OSPEED=short])
1010 AC_MSG_RESULT($NCURSES_OSPEED)
1011 AC_SUBST(NCURSES_OSPEED)
1012
1013 ###   use option --with-mmask-t to override mmask_t's type
1014 AC_MSG_CHECKING(for type of mmask_t)
1015 AC_ARG_WITH(mmask-t,
1016         [  --with-mmask-t=TYPE     override type of mmask_t],
1017         [NCURSES_MMASK_T="$withval"],
1018         [NCURSES_MMASK_T=$cf_dft_mmask_t])
1019 AC_MSG_RESULT($NCURSES_MMASK_T)
1020
1021 ###   use option --with-ccharw-max to override CCHARW_MAX size
1022 AC_MSG_CHECKING(for size CCHARW_MAX)
1023 AC_ARG_WITH(ccharw-max,
1024         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1025         [NCURSES_CCHARW_MAX="$withval"],
1026         [NCURSES_CCHARW_MAX=5])
1027 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1028 AC_SUBST(NCURSES_CCHARW_MAX)
1029
1030 AC_CHECK_SIZEOF([signed char], 0)
1031 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1032         NCURSES_SBOOL="signed char"
1033 else
1034         NCURSES_SBOOL="char"
1035 fi
1036 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1037 AC_ARG_ENABLE(signed-char,
1038         [  --enable-signed-char    compile using signed Boolean's in term.h],
1039         [with_signed_char=$enableval],
1040         [with_signed_char=no])
1041 AC_MSG_RESULT($with_signed_char)
1042 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1043 AC_SUBST(NCURSES_SBOOL)
1044
1045 ###   use option --with-tparm-arg to override tparm's argument type
1046 AC_MSG_CHECKING(for type of tparm args)
1047 AC_ARG_WITH(tparm-arg,
1048         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1049         [NCURSES_TPARM_ARG="$withval"],
1050         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1051 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1052 AC_SUBST(NCURSES_TPARM_ARG)
1053
1054 ### Enable compiling-in rcs id's
1055 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1056 AC_ARG_WITH(rcs-ids,
1057         [  --with-rcs-ids          compile-in RCS identifiers],
1058         [with_rcs_ids=$withval],
1059         [with_rcs_ids=no])
1060 AC_MSG_RESULT($with_rcs_ids)
1061 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1062
1063 ###############################################################################
1064 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1065
1066 ###############################################################################
1067 CF_HELP_MESSAGE(Extensions:)
1068
1069 ### Note that some functions (such as const) are normally disabled anyway.
1070 AC_MSG_CHECKING(if you want to build with function extensions)
1071 AC_ARG_ENABLE(ext-funcs,
1072         [  --disable-ext-funcs     disable function-extensions],
1073         [with_ext_funcs=$enableval],
1074         [with_ext_funcs=yes])
1075 AC_MSG_RESULT($with_ext_funcs)
1076 if test "x$with_ext_funcs" = xyes ; then
1077         NCURSES_EXT_FUNCS=1
1078         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1079         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1080         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1081         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1082         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1083         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1084         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1085         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1086         AC_DEFINE(HAVE_USE_EXTENDED_NAMES,1,[Define to 1 to enable use_extended_names() function in test-programs])
1087         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1088         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1089         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1090         GENERATED_EXT_FUNCS=generated
1091         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1092 else
1093         NCURSES_EXT_FUNCS=0
1094         GENERATED_EXT_FUNCS=
1095 fi
1096 AC_SUBST(NCURSES_EXT_FUNCS)
1097 AC_SUBST(GENERATED_EXT_FUNCS)
1098
1099 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1100 AC_ARG_ENABLE(sp-funcs,
1101         [  --enable-sp-funcs       enable SCREEN-extensions],
1102         [with_sp_funcs=$enableval],
1103         [with_sp_funcs=$cf_dft_ext_spfuncs])
1104 AC_MSG_RESULT($with_sp_funcs)
1105 if test "x$with_sp_funcs" = xyes ; then
1106         NCURSES_SP_FUNCS=1
1107         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1108         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1109         GENERATED_SP_FUNCS=generated
1110 else
1111         NCURSES_SP_FUNCS=0
1112         GENERATED_SP_FUNCS=
1113 fi
1114 AC_SUBST(NCURSES_SP_FUNCS)
1115 AC_SUBST(GENERATED_SP_FUNCS)
1116
1117 AC_MSG_CHECKING(if you want to build with terminal-driver)
1118 AC_ARG_ENABLE(term-driver,
1119         [  --enable-term-driver    enable terminal-driver],
1120         [with_term_driver=$enableval],
1121         [with_term_driver=no])
1122 AC_MSG_RESULT($with_term_driver)
1123 if test "x$with_term_driver" = xyes ; then
1124         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1125         if test "x$with_termlib" != xno ; then
1126                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1127         fi
1128         if test "x$with_sp_funcs" != xyes ; then
1129                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1130         fi
1131 fi
1132
1133 ###   use option --enable-const to turn on use of const beyond that in XSI.
1134 AC_MSG_CHECKING(for extended use of const keyword)
1135 AC_ARG_ENABLE(const,
1136         [  --enable-const          compile with extra/non-standard const],
1137         [with_ext_const=$enableval],
1138         [with_ext_const=$cf_dft_ext_const])
1139 AC_MSG_RESULT($with_ext_const)
1140 NCURSES_CONST='/*nothing*/'
1141 if test "x$with_ext_const" = xyes ; then
1142         NCURSES_CONST=const
1143 fi
1144 AC_SUBST(NCURSES_CONST)
1145
1146 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1147 AC_MSG_CHECKING(if you want to use extended colors)
1148 AC_ARG_ENABLE(ext-colors,
1149         [  --enable-ext-colors     compile for 256-color support],
1150         [with_ext_colors=$enableval],
1151         [with_ext_colors=$cf_dft_ext_colors])
1152 AC_MSG_RESULT($with_ext_colors)
1153 NCURSES_EXT_COLORS=0
1154 if test "x$with_ext_colors" = xyes ; then
1155         if test "x$with_widec" != xyes ; then
1156                 AC_MSG_WARN(This option applies only to wide-character library)
1157         else
1158                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1159                 CF_NCURSES_ABI_6
1160                 NCURSES_EXT_COLORS=1
1161                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1162                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1163                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1164                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1165         fi
1166 fi
1167 AC_SUBST(NCURSES_EXT_COLORS)
1168
1169 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1170 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1171 AC_ARG_ENABLE(ext-mouse,
1172         [  --enable-ext-mouse      compile for extended mouse-encoding],
1173         [with_ext_mouse=$enableval],
1174         [with_ext_mouse=$cf_dft_ext_mouse])
1175 AC_MSG_RESULT($with_ext_mouse)
1176 NCURSES_MOUSE_VERSION=1
1177 if test "x$with_ext_mouse" = xyes ; then
1178         NCURSES_MOUSE_VERSION=2
1179         CF_NCURSES_ABI_6
1180 fi
1181 AC_SUBST(NCURSES_MOUSE_VERSION)
1182
1183 ###   use option --enable-ext-putwin to turn on extended screendumps
1184 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1185 AC_ARG_ENABLE(ext-putwin,
1186         [  --enable-ext-putwin     compile with extended putwin/screendump],
1187         [with_ext_putwin=$enableval],
1188         [with_ext_putwin=$cf_dft_ext_putwin])
1189 AC_MSG_RESULT($with_ext_putwin)
1190 if test "x$with_ext_putwin" = xyes ; then
1191         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1192 fi
1193
1194 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1195 AC_ARG_ENABLE(no-padding,
1196         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1197         [with_no_padding=$enableval],
1198         [with_no_padding=$with_ext_funcs])
1199 AC_MSG_RESULT($with_no_padding)
1200 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1201
1202 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1203 AC_MSG_CHECKING(if you want SIGWINCH handler)
1204 AC_ARG_ENABLE(sigwinch,
1205         [  --enable-sigwinch       compile with SIGWINCH handler],
1206         [with_sigwinch=$enableval],
1207         [with_sigwinch=$with_ext_funcs])
1208 AC_MSG_RESULT($with_sigwinch)
1209 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1210
1211 ###   use option --enable-tcap-names to allow user to define new capabilities
1212 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1213 AC_ARG_ENABLE(tcap-names,
1214         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1215         [with_tcap_names=$enableval],
1216         [with_tcap_names=$with_ext_funcs])
1217 AC_MSG_RESULT($with_tcap_names)
1218 NCURSES_XNAMES=0
1219 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1220 AC_SUBST(NCURSES_XNAMES)
1221
1222 ##############################################################################
1223 CF_HELP_MESSAGE(Reentrant Code:)
1224 CF_WITH_PTHREAD
1225
1226 if test "x$with_pthread" != xno; then
1227         AC_CHECK_FUNC(pthread_kill,[
1228                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1229                 AC_ARG_ENABLE(pthreads-eintr,
1230                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1231                         [use_pthreads_eintr=$enableval],
1232                         [use_pthreads_eintr=no])
1233                 AC_MSG_RESULT($use_pthreads_eintr)
1234                 if test "x$use_pthreads_eintr" = xyes ; then
1235                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1236                 fi])
1237
1238         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1239         AC_ARG_ENABLE(weak-symbols,
1240                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1241                 [use_weak_symbols=$enableval],
1242                 [use_weak_symbols=no])
1243         AC_MSG_RESULT($use_weak_symbols)
1244         if test "x$use_weak_symbols" = xyes ; then
1245                 CF_WEAK_SYMBOLS
1246         else
1247                 cf_cv_weak_symbols=no
1248         fi
1249
1250         if test "x$cf_cv_weak_symbols" = xyes ; then
1251                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1252         fi
1253 fi
1254
1255 PTHREAD=
1256 if test "x$with_pthread" = "xyes" ; then
1257         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1258         enable_reentrant=yes
1259         if test "x$cf_cv_weak_symbols" = xyes ; then
1260                 PTHREAD=-lpthread
1261                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1262         fi
1263 fi
1264 AC_SUBST(PTHREAD)
1265
1266 # Reentrant code has to be opaque; there's little advantage to making ncurses
1267 # opaque outside of that, so there is no --enable-opaque option.  We can use
1268 # this option without --with-pthreads, but this will be always set for
1269 # pthreads.
1270 AC_MSG_CHECKING(if you want reentrant code)
1271 AC_ARG_ENABLE(reentrant,
1272         [  --enable-reentrant      compile with reentrant code],
1273         [with_reentrant=$enableval],
1274         [with_reentrant=no])
1275 AC_MSG_RESULT($with_reentrant)
1276 if test "x$with_reentrant" = xyes ; then
1277         cf_cv_enable_reentrant=1
1278         cf_cv_enable_opaque="NCURSES_INTERNALS"
1279         NCURSES_SIZE_T=int
1280         if test "x$cf_cv_weak_symbols" = xyes ; then
1281                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1282                 CF_ADD_LIB(pthread,TEST_LIBS)
1283                 CF_ADD_LIB(pthread,TEST_LIBS2)
1284                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1285         else
1286                 # when not using weak symbols but with_reentrant,
1287                 # add 't' to the library suffix on all platforms
1288                 # except cygwin, where we only do that if ALSO
1289                 # compiling with full thread support.
1290                 case "$host" in
1291                 (*cygwin* | *msys*)
1292                         if test "$with_pthread" = "yes" ; then
1293                                 if test "x$disable_lib_suffixes" = "xno" ; then
1294                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1295                                 fi
1296                         fi ;;
1297                 (*)
1298                         if test "x$disable_lib_suffixes" = "xno" ; then
1299                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1300                         fi
1301                         ;;
1302                 esac
1303         fi
1304         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1305         CF_NCURSES_ABI_6
1306 else
1307         cf_cv_enable_reentrant=0
1308         cf_cv_enable_opaque="NCURSES_OPAQUE"
1309         NCURSES_SIZE_T=short
1310 fi
1311 AC_SUBST(cf_cv_enable_reentrant)
1312 AC_SUBST(cf_cv_enable_opaque)
1313
1314 AC_SUBST(NCURSES_SIZE_T)
1315
1316 AC_MSG_CHECKING(if you want opaque curses-library structures)
1317 CF_ARG_ENABLE(opaque-curses,
1318         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1319         [enable_opaque_curses=yes],[
1320          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1321          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=no
1322         ])
1323 AC_MSG_RESULT($enable_opaque_curses)
1324
1325 test "$cf_cv_enable_reentrant" = 1 && \
1326 test "$enable_opaque_curses" = no && \
1327 AC_MSG_ERROR(reentrant configuration requires opaque library)
1328
1329 AC_MSG_CHECKING(if you want opaque form-library structures)
1330 AC_ARG_ENABLE(opaque-form,
1331         [  --enable-opaque-form    make form-library structures "opaque"],
1332         [enable_opaque_form=yes],[enable_opaque_form=no])
1333 AC_MSG_RESULT($enable_opaque_form)
1334
1335 AC_MSG_CHECKING(if you want opaque menu-library structures)
1336 AC_ARG_ENABLE(opaque-menu,
1337         [  --enable-opaque-menu    make menu-library structures "opaque"],
1338         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1339 AC_MSG_RESULT($enable_opaque_menu)
1340
1341 AC_MSG_CHECKING(if you want opaque panel-library structures)
1342 AC_ARG_ENABLE(opaque-panel,
1343         [  --enable-opaque-panel   make panel-library structures "opaque"],
1344         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1345 AC_MSG_RESULT($enable_opaque_panel)
1346
1347 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1348 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1349 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1350 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1351
1352 AC_SUBST(NCURSES_OPAQUE)
1353 AC_SUBST(NCURSES_OPAQUE_FORM)
1354 AC_SUBST(NCURSES_OPAQUE_MENU)
1355 AC_SUBST(NCURSES_OPAQUE_PANEL)
1356
1357 ### Allow using a different wrap-prefix
1358 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1359         AC_MSG_CHECKING(for prefix used to wrap public variables)
1360         AC_ARG_WITH(wrap-prefix,
1361                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1362                 [NCURSES_WRAP_PREFIX=$withval],
1363                 [NCURSES_WRAP_PREFIX=_nc_])
1364         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1365 else
1366         NCURSES_WRAP_PREFIX=_nc_
1367 fi
1368 AC_SUBST(NCURSES_WRAP_PREFIX)
1369 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1370
1371 ###############################################################################
1372 # These options are relatively safe to experiment with.
1373 CF_HELP_MESSAGE(Development Code:)
1374 AC_MSG_CHECKING(if you want all development code)
1375 AC_ARG_WITH(develop,
1376         [  --without-develop       disable development options],
1377         [with_develop=$withval],
1378         [with_develop=no])
1379 AC_MSG_RESULT($with_develop)
1380
1381 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1382 AC_MSG_CHECKING(if you want hard-tabs code)
1383 AC_ARG_ENABLE(hard-tabs,
1384         [  --enable-hard-tabs      compile with hard-tabs code],,
1385         [enable_hard_tabs=$with_develop])
1386 AC_MSG_RESULT($enable_hard_tabs)
1387 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1388
1389 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1390 AC_MSG_CHECKING(if you want limited support for xmc)
1391 AC_ARG_ENABLE(xmc-glitch,
1392         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1393         [enable_xmc_glitch=$with_develop])
1394 AC_MSG_RESULT($enable_xmc_glitch)
1395 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1396
1397 ###############################################################################
1398 # These are just experimental, probably should not be in a package:
1399 CF_HELP_MESSAGE(Experimental Code:)
1400
1401 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1402 AC_ARG_ENABLE(assumed-color,
1403         [  --disable-assumed-color do not assume anything about default-colors],
1404         [with_assumed_color=$enableval],
1405         [with_assumed_color=yes])
1406 AC_MSG_RESULT($with_assumed_color)
1407 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1408
1409 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1410 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1411 AC_ARG_ENABLE(hashmap,
1412         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1413         [with_hashmap=$enableval],
1414         [with_hashmap=yes])
1415 AC_MSG_RESULT($with_hashmap)
1416 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1417
1418 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1419 AC_MSG_CHECKING(if you want colorfgbg code)
1420 AC_ARG_ENABLE(colorfgbg,
1421         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1422         [with_colorfgbg=$enableval],
1423         [with_colorfgbg=no])
1424 AC_MSG_RESULT($with_colorfgbg)
1425 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1426
1427 ###   use option --enable-interop to turn on use of bindings used for interop
1428 AC_MSG_CHECKING(if you want interop bindings)
1429 AC_ARG_ENABLE(interop,
1430         [  --enable-interop        compile-in interop bindings],
1431         [with_exp_interop=$enableval],
1432         [with_exp_interop=$cf_dft_interop])
1433 AC_MSG_RESULT($with_exp_interop)
1434
1435 NCURSES_INTEROP_FUNCS=0
1436 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1437 AC_SUBST(NCURSES_INTEROP_FUNCS)
1438
1439
1440 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1441 AC_ARG_ENABLE(safe-sprintf,
1442         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1443         [with_safe_sprintf=$enableval],
1444         [with_safe_sprintf=no])
1445 AC_MSG_RESULT($with_safe_sprintf)
1446
1447 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1448 # when hashmap is used scroll hints are useless
1449 if test "$with_hashmap" = no ; then
1450 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1451 AC_ARG_ENABLE(scroll-hints,
1452         [  --disable-scroll-hints  compile without scroll-hints code],
1453         [with_scroll_hints=$enableval],
1454         [with_scroll_hints=yes])
1455 AC_MSG_RESULT($with_scroll_hints)
1456 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1457 fi
1458
1459 AC_MSG_CHECKING(if you want wgetch-events code)
1460 AC_ARG_ENABLE(wgetch-events,
1461         [  --enable-wgetch-events  compile with wgetch-events code],
1462         [with_wgetch_events=$enableval],
1463         [with_wgetch_events=no])
1464 AC_MSG_RESULT($with_wgetch_events)
1465 test "x$with_wgetch_events" = xyes && AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1466
1467 ###############################################################################
1468 CF_HELP_MESSAGE(Testing/development Options:)
1469
1470 ###     use option --disable-echo to suppress full display compiling commands
1471 CF_DISABLE_ECHO
1472 if test "x$enable_echo" = xyes; then
1473         ECHO_LINK=
1474 else
1475         ECHO_LINK='@ echo linking $@ ... ;'
1476         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1477         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1478 fi
1479 AC_SUBST(ECHO_LINK)
1480
1481 # --disable-stripping is used for debugging
1482 CF_INSTALL_OPTS
1483
1484 # If we're avoiding relinking of shared libraries during install, that is to
1485 # avoid modifying the build-tree.  For the same reason, avoid doing ranlib if
1486 # the install program has "-p" (for preserving timestamps).
1487 cf_cv_do_reranlib=yes
1488 if test "x$cf_cv_install_p" = xyes
1489 then
1490         if test "x$cf_cv_do_relink" != xyes
1491         then
1492                 cf_cv_do_reranlib=no
1493                 INSTALL_OPT_P="-p"
1494                 INSTALL_LIB="$INSTALL_LIB $INSTALL_OPT_P"
1495         fi
1496 fi
1497 AC_SUBST(INSTALL_OPT_P)
1498
1499 ###     use option --enable-warnings to turn on all gcc warnings
1500 AC_MSG_CHECKING(if you want to see compiler warnings)
1501 AC_ARG_ENABLE(warnings,
1502         [  --enable-warnings       build: turn on GCC compiler warnings],
1503         [with_warnings=$enableval])
1504 AC_MSG_RESULT($with_warnings)
1505
1506 if test "x$with_warnings" = "xyes"; then
1507         CF_ADD_ADAFLAGS(-gnatg)
1508         CF_GCC_WARNINGS(Wno-unknown-pragmas Wswitch-enum)
1509         if test "x$cf_with_cxx" = xyes ; then
1510                 CF_GXX_WARNINGS(Wno-unused)
1511         fi
1512 fi
1513 CF_GCC_ATTRIBUTES
1514 CF_ENABLE_STRING_HACKS
1515
1516 ###     use option --enable-assertions to turn on generation of assertion code
1517 AC_MSG_CHECKING(if you want to enable runtime assertions)
1518 AC_ARG_ENABLE(assertions,
1519         [  --enable-assertions     test: turn on generation of assertion code],
1520         [with_assertions=$enableval],
1521         [with_assertions=no])
1522 AC_MSG_RESULT($with_assertions)
1523 if test -n "$GCC"
1524 then
1525         if test "$with_assertions" = no
1526         then
1527                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1528         else
1529                 CF_ADD_ADAFLAGS(-gnata)
1530         fi
1531 fi
1532
1533 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1534 CF_DISABLE_LEAKS
1535 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1536
1537 ###     use option --enable-expanded to generate certain macros as functions
1538 AC_ARG_ENABLE(expanded,
1539         [  --enable-expanded       test: generate functions for certain macros],
1540         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1541
1542 ###     use option --disable-macros to suppress macros in favor of functions
1543 AC_ARG_ENABLE(macros,
1544         [  --disable-macros        test: use functions rather than macros],
1545         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1546
1547 # Normally we only add trace() to the debug-library.  Allow this to be
1548 # extended to all models of the ncurses library:
1549 cf_all_traces=no
1550 case "$CFLAGS $CPPFLAGS" in
1551 (*-DTRACE*)
1552         cf_all_traces=yes
1553         ;;
1554 esac
1555
1556 AC_MSG_CHECKING(whether to add trace feature to all models)
1557 AC_ARG_WITH(trace,
1558 [  --with-trace            test: add trace() function to all models of ncurses],
1559 [cf_with_trace=$withval],
1560 [cf_with_trace=$cf_all_traces])
1561 AC_MSG_RESULT($cf_with_trace)
1562
1563 if test "x$cf_with_trace" = xyes ; then
1564         LIB_TRACING=all
1565         ADA_TRACE=TRUE
1566         CF_ADD_CFLAGS(-DTRACE)
1567         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1568 else
1569         LIB_TRACING=DEBUG
1570         ADA_TRACE=FALSE
1571 fi
1572
1573 AC_SUBST(ADA_TRACE)
1574
1575 CF_DISABLE_GNAT_PROJECTS
1576
1577 ###     Checks for libraries.
1578 case $cf_cv_system_name in
1579 (*mingw32*|*mingw64*)
1580         CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1581         LIBS=" -lpsapi $LIBS"
1582         ;;
1583 (*)
1584 AC_CHECK_FUNC(gettimeofday,
1585         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1586
1587 AC_CHECK_LIB(bsd, gettimeofday,
1588         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1589         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1590         ;;
1591 esac
1592
1593 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1594 AC_SUBST(MATH_LIB)
1595
1596 ###     Checks for header files.
1597 AC_STDC_HEADERS
1598 AC_HEADER_DIRENT
1599 AC_HEADER_TIME
1600 CF_REGEX
1601
1602 dnl These are some other potentially nonportable headers.
1603 AC_CHECK_HEADERS( \
1604 fcntl.h \
1605 getopt.h \
1606 limits.h \
1607 locale.h \
1608 math.h \
1609 poll.h \
1610 sys/bsdtypes.h \
1611 sys/ioctl.h \
1612 sys/param.h \
1613 sys/poll.h \
1614 sys/select.h \
1615 sys/time.h \
1616 sys/times.h \
1617 ttyent.h \
1618 unistd.h \
1619 wctype.h \
1620 )
1621
1622 CF_GETOPT_HEADER
1623
1624 # check for ISC (this may also define _POSIX_SOURCE)
1625 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1626 if test "x$ISC" = xyes ; then
1627         AC_CHECK_LIB(cposix,main)
1628         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1629 fi
1630
1631 CF_SYS_TIME_SELECT
1632
1633 ###     checks for compiler characteristics
1634 AC_LANG_C
1635 AC_C_CONST
1636 CF_C_INLINE(NCURSES_INLINE,1200)
1637 CF_SIG_ATOMIC_T
1638
1639 if test $NCURSES_CHTYPE = auto ; then
1640         CF_TYPEOF_CHTYPE
1641 else
1642         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1643 fi
1644 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1645 AC_SUBST(cf_cv_typeof_chtype)
1646
1647 CF_UNSIGNED_LITERALS
1648 cf_cv_1UL="1"
1649 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1650 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1651 AC_SUBST(cf_cv_1UL)
1652
1653 if test $NCURSES_MMASK_T = auto ; then
1654         cf_cv_typeof_mmask_t=long
1655 else
1656         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1657 fi
1658 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1659 AC_SUBST(cf_cv_typeof_mmask_t)
1660
1661 ###     Checks for external-data
1662 CF_ERRNO
1663 CF_LINK_DATAONLY
1664
1665 ###     Checks for library functions.
1666 AC_CHECK_FUNCS( \
1667 getcwd \
1668 getegid \
1669 geteuid \
1670 getopt \
1671 getttynam \
1672 issetugid \
1673 poll \
1674 putenv \
1675 remove \
1676 select \
1677 setbuf \
1678 setbuffer \
1679 setenv \
1680 setvbuf \
1681 sigaction \
1682 sigvec \
1683 strdup \
1684 strstr \
1685 tcgetpgrp \
1686 tdestroy \
1687 times \
1688 tsearch \
1689 vsnprintf \
1690 )
1691
1692 if test "x$ac_cv_func_getopt" = xno && \
1693    test "x$cf_with_progs$cf_with_tests" != xnono; then
1694         AC_MSG_ERROR(getopt is required for building programs)
1695 fi
1696
1697 if test "x$with_safe_sprintf" = xyes
1698 then
1699         if test "x$ac_cv_func_vsnprintf" = xyes
1700         then
1701                 AC_MSG_WARN(will use vsnprintf instead of safe-sprintf option)
1702         else
1703                 AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1704         fi
1705 fi
1706
1707 if test "x$with_getcap" = "xyes" ; then
1708         CF_CGETENT
1709 fi
1710
1711 CF_ISASCII
1712 CF_STRUCT_SIGACTION
1713 CF_FUNC_NANOSLEEP
1714 CF_FUNC_TERMIOS
1715 CF_FUNC_VSSCANF
1716 CF_MKSTEMP
1717
1718 # setup for prototype of fallback for vsscanf()
1719 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1720
1721 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1722 if test "x$cross_compiling" = xyes ; then
1723         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1724 else
1725         AC_FUNC_SETVBUF_REVERSED
1726 fi
1727 AC_CHECK_TYPE(intptr_t, long)
1728 AC_CHECK_TYPE(ssize_t, int)
1729 CF_TYPE_SIGACTION
1730 CF_SIZECHANGE
1731 CF_FUNC_MEMMOVE
1732 CF_FUNC_POLL
1733 CF_VA_COPY
1734 AC_FUNC_VFORK
1735
1736 # special check for test/ditto.c
1737 CF_FUNC_OPENPTY
1738 if test "$cf_cv_func_openpty" != no ; then
1739         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1740         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1741         if test "x$cf_cv_lib_util" = xyes ; then
1742                 CF_ADD_LIB(util,TEST_LIBS)
1743         fi
1744 fi
1745 AC_SUBST(TEST_LIBS)
1746 AC_SUBST(TEST_LIBS2)
1747
1748 if test "$with_hashed_db" != no ; then
1749         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1750         CF_HASHED_DB($with_hashed_db)
1751 fi
1752
1753 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1754 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1755         CF_STRIP_G_OPT(CFLAGS)
1756         CF_STRIP_G_OPT(CXXFLAGS)
1757 fi
1758
1759 # Just in case, check if the C compiler has a bool type.
1760 CF_BOOL_DECL(cf_cv_cc_bool_type)
1761
1762 # Check for C++ compiler characteristics (and ensure that it's there!)
1763 if test -n "$CXX" ; then
1764         AC_LANG_CPLUSPLUS
1765         CF_STDCPP_LIBRARY
1766         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1767
1768         case $GXX_VERSION in
1769         (1*|2.[0-6]*)
1770                 cf_cxx_library=yes
1771                 ;;
1772         (*-2.7*|2.7*)
1773                 CF_GPP_LIBRARY
1774                 ;;
1775         (*)
1776                 cf_cxx_library=no
1777                 ;;
1778         esac
1779
1780         AC_CHECK_HEADERS(typeinfo)
1781         CF_CXX_IOSTREAM_NAMESPACE
1782         CF_BOOL_DECL
1783         CF_BOOL_SIZE
1784         CF_ETIP_DEFINES
1785         CF_CPP_PARAM_INIT
1786         CF_CPP_STATIC_CAST
1787         CF_CXX_AR_FLAGS
1788 else
1789         cf_cxx_library=no
1790         cf_cv_builtin_bool=1
1791
1792         # Just because we are not configuring against C++ right now does not
1793         # mean that a user will not want to use C++.  Some distributors disable
1794         # the C++ portion of this configuration as a shortcut (or just to avoid
1795         # compiling the demo in the c++ directory).  So we need a reasonable
1796         # default for the 'bool' type.
1797         #
1798         # Caveat: since the storage of the bool type is not standardized, it
1799         # may change.
1800
1801         if test "$NCURSES_BOOL" != auto ; then
1802                 cf_cv_type_of_bool=$NCURSES_BOOL
1803                 cf_cv_header_stdbool_h=0
1804         else
1805                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1806                         CF_BOOL_SIZE
1807                 else
1808                         AC_MSG_CHECKING(for fallback type of bool)
1809                         case "$host_cpu" in
1810                         (i?86)  cf_cv_type_of_bool=char ;;
1811                         (*)     cf_cv_type_of_bool=int  ;;
1812                         esac
1813                         AC_MSG_RESULT($cf_cv_type_of_bool)
1814                 fi
1815         fi
1816 fi
1817 AC_SUBST(CXXLIBS)
1818
1819 # If the C compiler did not declare bool, and we did not determine that the C++
1820 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1821 # ncurses library use the same type as C++ bool.  Note that this allows one to
1822 # specify the type of bool in a configure-script option and postpone
1823 # integration with the C++ compiler provided that the types are compatible.
1824 USE_CXX_BOOL=1
1825 if test $cf_cv_cc_bool_type = 1
1826 then
1827         # oops: C has a bool.  Unlikely, but C++ could differ.
1828         USE_CXX_BOOL=0
1829 elif test $cf_cv_builtin_bool = 0
1830 then
1831         # C++ has no bool
1832         USE_CXX_BOOL=0
1833 else
1834         # this is the normal case
1835         USE_CXX_BOOL='defined(__cplusplus)'
1836 fi
1837 AC_SUBST(USE_CXX_BOOL)
1838
1839 CF_HELP_MESSAGE(Ada95 Binding Options:)
1840
1841 dnl If the Ada95 source-tree is present, add that to the build unless it will
1842 dnl not work, or was not requested.
1843 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1844
1845 dnl libtool does not know anything about GNAT, though a change made in 1998
1846 dnl provided for it "someday".  Disable the ada subtree if we are using
1847 dnl libtool -TD 20070714
1848         if test "$cf_with_ada" != "no" ; then
1849                 if test "$with_libtool" != "no"; then
1850                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1851                         cf_with_ada=no
1852                 fi
1853         fi
1854
1855 dnl Check for availability of GNU Ada Translator (GNAT).
1856 dnl At the moment we support no other Ada95 compiler.
1857         if test "$cf_with_ada" != "no" ; then
1858                 CF_PROG_GNAT
1859                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1860                         CF_ADD_ADAFLAGS(-gnatpn)
1861                         CF_FIXUP_ADAFLAGS
1862
1863                         CF_GNATPREP_OPT_T
1864
1865                         CF_GNAT_GENERICS
1866                         CF_GNAT_SIGINT
1867                         CF_GNAT_PROJECTS
1868
1869                         CF_WITH_ADA_COMPILER
1870
1871                         cf_ada_package=terminal_interface
1872                         AC_SUBST(cf_ada_package)
1873
1874                         CF_WITH_ADA_INCLUDE
1875                         CF_WITH_ADA_OBJECTS
1876                         CF_WITH_ADA_SHAREDLIB
1877                 fi
1878         fi
1879 else
1880         cf_with_ada=no
1881 fi
1882
1883 # do this "late" to avoid conflict with header-checks
1884 if test "x$with_widec" = xyes ; then
1885         AC_CHECK_SIZEOF(wchar_t)
1886 fi
1887
1888 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1889 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1890 ###
1891 ### ticlib modules may be a separate library, otherwise contained in termlib.
1892 ### termlib modules may be a separate library, otherwise contained in ncurses.
1893 ###
1894 ### The of "+" or " " between the tokens controls the way the script
1895 ### chooses to split module lists into libraries.
1896 ###
1897 ### (see CF_LIB_RULES).
1898 AC_MSG_CHECKING(for library subsets)
1899 LIB_SUBSETS=
1900
1901 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1902         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1903         if test "$with_ticlib" != no ; then
1904                 LIB_SUBSETS="${LIB_SUBSETS} "
1905         else
1906                 LIB_SUBSETS="${LIB_SUBSETS}+"
1907         fi
1908 fi
1909
1910 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1911 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1912
1913 if test "$with_termlib" != no ; then
1914         LIB_SUBSETS="${LIB_SUBSETS} "
1915 else
1916         LIB_SUBSETS="${LIB_SUBSETS}+"
1917 fi
1918
1919 LIB_SUBSETS="${LIB_SUBSETS}base"
1920
1921 # Most term-driver calls are to tinfo, but some like init_pair are to the
1922 # base library (so it resides in base).
1923 if test "$with_term_driver" != no ; then
1924         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1925         case $cf_cv_system_name in
1926         (*mingw32*|*mingw64*)
1927                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1928                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
1929                 ;;
1930         (*)
1931                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1932                 ;;
1933         esac
1934 fi
1935
1936 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1937 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1938
1939 AC_MSG_RESULT($LIB_SUBSETS)
1940
1941 ### Construct the list of include-directories to be generated
1942 CF_INCLUDE_DIRS
1943 CF_ADA_INCLUDE_DIRS
1944
1945 ### Build up pieces for makefile rules
1946 AC_MSG_CHECKING(default library suffix)
1947 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1948 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1949 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1950
1951 AC_MSG_CHECKING(default library-dependency suffix)
1952 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1953 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1954 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1955
1956 AC_MSG_CHECKING(default object directory)
1957 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1958 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1959 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1960
1961 if test "x$cf_with_cxx" = xyes ; then
1962 AC_MSG_CHECKING(c++ library-dependency suffix)
1963 if test "$with_libtool" != "no"; then
1964         # libtool thinks it can make c++ shared libraries (perhaps only g++)
1965         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1966 elif test "$with_shared_cxx" != "no"; then
1967         # also for g++ users...
1968         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1969 else
1970         # we normally make a static library because C/C++ library rules differ
1971         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
1972 fi
1973 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1974 AC_SUBST(CXX_LIB_SUFFIX)
1975 fi
1976
1977 # do not want -ldl in build except as needed for -lncurses dependency
1978 if test "x$with_dlsym" = xyes ; then
1979 if test $DFT_LWR_MODEL = shared || \
1980    test $DFT_LWR_MODEL = libtool ; then
1981         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1982 fi
1983 fi
1984 ### Set up low-level terminfo dependencies for makefiles.
1985
1986 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1987 # do not need libdl
1988 TICS_LIST=
1989 if test "x$with_dlsym" = xyes ; then
1990         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1991 fi
1992
1993 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
1994 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
1995 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
1996 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
1997 then
1998         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
1999 fi
2000 AC_SUBST(USE_ARG_SUFFIX)
2001 AC_SUBST(USE_CFG_SUFFIX)
2002 AC_SUBST(USE_LIB_SUFFIX)
2003
2004 if test "$with_ticlib" != no ; then
2005
2006         if test "x$with_ticlib" != xyes ; then
2007                 TICS_NAME=$with_ticlib
2008                 TICS_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
2009                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2010                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2011                 TICS_LIB_SUFFIX="${with_ticlib}"
2012         else
2013                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
2014                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
2015                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
2016                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
2017         fi
2018         TICS_LDFLAGS="-L${LIB_DIR}"
2019         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
2020 else
2021         TICS_SUFFIX=${DFT_LIB_SUFFIX}
2022         TICS_LDFLAGS="-L${LIB_DIR}"
2023         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2024 fi
2025 AC_SUBST(TICS_ARG_SUFFIX)
2026 AC_SUBST(TICS_DEP_SUFFIX)
2027 AC_SUBST(TICS_LIB_SUFFIX)
2028 AC_SUBST(TICS_LDFLAGS)
2029 AC_SUBST(TICS_LIBS)
2030
2031 if test "$with_termlib" != no ; then
2032
2033         if test "x$with_termlib" != xyes ; then
2034                 TINFO_NAME=$with_termlib
2035                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
2036                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2037                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2038                 TINFO_LIB_SUFFIX="${with_termlib}"
2039         else
2040                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2041                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2042                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2043                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2044         fi
2045
2046         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2047         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2048         if test "$DFT_LWR_MODEL" = "libtool"; then
2049                 TEST_ARGS="${TEST_DEPS}"
2050                 TEST_ARG2="${TEST_DEP2}"
2051                 TINFO_LDFLAGS="-L${LIB_DIR}"
2052                 TINFO_LIBS="$TEST_ARGS"
2053                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2054                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2055         else
2056                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2057                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2058                 if test "x$with_term_driver" != xno ; then
2059                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2060                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2061                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2062                 else
2063                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2064                         TINFO_LIBS="$TEST_ARGS"
2065                 fi
2066                 TINFO_LDFLAGS="-L${LIB_DIR}"
2067                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2068         fi
2069 else
2070         # the next lines are needed for linking libtic over libncurses
2071         TINFO_NAME=${LIB_NAME}
2072         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2073         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2074         if test "x$with_tic_depends" = xyes ; then
2075                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2076         else
2077                 TICS_LIST="$SHLIB_LIST"
2078         fi
2079
2080         TINFO_LDFLAGS="-L${LIB_DIR}"
2081         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2082 fi
2083
2084 if test "$DFT_LWR_MODEL" = shared ; then
2085         case $cf_cv_system_name in
2086         (cygwin*|msys*)
2087                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2088                 TINFO_SUFFIX=.dll
2089                 ;;
2090         esac
2091 fi
2092
2093 AC_SUBST(TINFO_ARG_SUFFIX)
2094 AC_SUBST(TINFO_DEP_SUFFIX)
2095 AC_SUBST(TINFO_LIB_SUFFIX)
2096 AC_SUBST(TINFO_LDFLAGS)
2097 AC_SUBST(TINFO_LIBS)
2098
2099 if test "x$with_dlsym" = xyes ; then
2100         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2101 fi
2102
2103 if test "$DFT_LWR_MODEL" = "libtool"; then
2104         OBJEXT=lo
2105 fi
2106
2107 # needed for Ada95
2108 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2109 AC_SUBST(TINFO_LDFLAGS2)
2110
2111 case $DFT_LWR_MODEL in
2112 (normal|debug|profile)
2113         CF_LDFLAGS_STATIC
2114         ;;
2115 esac
2116
2117 AC_MSG_CHECKING(where we will install curses.h)
2118 AC_SUBST(includesubdir)
2119 includesubdir=
2120 if test "$with_overwrite" = no && \
2121  ( test "x$includedir" = 'x${prefix}/include' || \
2122    test "x$includedir" = "x${prefix}/include" )
2123 then
2124         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2125 fi
2126 AC_MSG_RESULT(${includedir}${includesubdir})
2127
2128 ### Resolve a conflict between normal and wide-curses by forcing applications
2129 ### that will need libutf8 to add it to their configure script.
2130 if test "$with_overwrite" != no ; then
2131 if test "$NCURSES_LIBUTF8" = 1 ; then
2132         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2133         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2134 fi
2135 fi
2136 WITH_OVERWRITE=$with_overwrite
2137
2138 AC_SUBST(WITH_OVERWRITE)
2139 AC_SUBST(TICS_LIST)
2140 AC_SUBST(TINFO_LIST)
2141 AC_SUBST(SHLIB_LIST)
2142
2143 # used to separate tack out of the tree
2144 NCURSES_TREE=
2145 AC_SUBST(NCURSES_TREE)
2146
2147 ### predefined stuff for the test programs
2148 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2149
2150 ### Construct the list of subdirectories for which we'll customize makefiles
2151 ### with the appropriate compile-rules.
2152
2153 CF_SRC_MODULES($modules_to_build)
2154
2155 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2156    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2157    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2158 fi
2159
2160 CF_DIRS_TO_MAKE
2161
2162 # symbols that differ when compiling Ada95 by itself.
2163 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2164 AC_SUBST(NCURSES_SHLIB2)
2165
2166 # values to use as strings
2167 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2168
2169 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2170
2171 ### Now that we're done running tests, add the compiler-warnings, if any
2172 CF_ADD_CFLAGS($EXTRA_CFLAGS)
2173
2174 ### Define substitutions for header files to avoid name-pollution
2175 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2176 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2177 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2178 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2179
2180 ################################################################################
2181 test "x$use_database" = xyes && \
2182 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2183
2184 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2185 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2186
2187 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2188 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2189 fi
2190 AC_SUBST(cross_compiling)
2191
2192 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
2193 if test -n "$FALLBACK_LIST"
2194 then
2195         if test "$TIC_PATH" = unknown
2196         then
2197                 AC_MSG_WARN(no tic program found for fallbacks)
2198         fi
2199 fi
2200 AC_SUBST(TIC_PATH)
2201
2202 if test "x$cf_with_tests" != xno ; then
2203         MAKE_TESTS=
2204 else
2205         MAKE_TESTS="#"
2206 fi
2207 AC_SUBST(MAKE_TESTS)
2208
2209 ADAHTML_DIR=../../doc/html/ada
2210 AC_SUBST(ADAHTML_DIR)
2211
2212 # these could be configurable, but are not currently
2213 PANEL_NAME=panel
2214 MENU_NAME=menu
2215 FORM_NAME=form
2216 CXX_NAME=ncurses++
2217
2218 AC_SUBST(PANEL_NAME)
2219 AC_SUBST(MENU_NAME)
2220 AC_SUBST(FORM_NAME)
2221 AC_SUBST(CXX_NAME)
2222
2223 # workaround for OS/2 (20151017)
2224 case $cf_cv_system_name in
2225 (os2*)
2226         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2227         ;;
2228 (*)
2229         LIBTOOL_OPTS_CXX=
2230         ;;
2231 esac
2232 AC_SUBST(LIBTOOL_OPTS_CXX)
2233
2234 # workaround for g++ versus Solaris (20131116)
2235 case $cf_cv_system_name in
2236 (solaris2*)
2237         case "x$CPPFLAGS" in
2238         (*-D_XOPEN_SOURCE_EXTENDED*)
2239                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2240                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2241                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2242                 ;;
2243         esac
2244         ;;
2245 esac
2246
2247 # Help to automatically enable the extended curses features when using either
2248 # the *-config or the ".pc" files by adding defines.
2249 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2250 PKG_CFLAGS=
2251 for cf_loop1 in $CPPFLAGS_after_XOPEN
2252 do
2253         cf_found=no
2254         for cf_loop2 in $CPPFLAGS_before_XOPEN
2255         do
2256                 if test "x$cf_loop1" = "x$cf_loop2"
2257                 then
2258                         cf_found=yes
2259                         break
2260                 fi
2261         done
2262         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2263 done
2264 AC_MSG_RESULT($PKG_CFLAGS)
2265 AC_SUBST(PKG_CFLAGS)
2266
2267 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2268 case "x$NCURSES_OSPEED" in
2269 (*short*)
2270         cf_compatible=1
2271         ;;
2272 (*)
2273         cf_compatible=0
2274         ;;
2275 esac
2276 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2277
2278 case "x$cf_cv_typeof_chtype" in
2279 (xshort|xint|xlong)
2280         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2281         ;;
2282 esac
2283
2284 case "x$cf_cv_typeof_mmask_t" in
2285 (xshort|xint|xlong)
2286         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2287         ;;
2288 esac
2289
2290 # substitute into misc/Makefile to suppress
2291 # (un)install.data from the
2292 # (un)install rules.
2293 if test "x$cf_with_db_install" = "xno"; then
2294         MISC_INSTALL_DATA=
2295         MISC_UNINSTALL_DATA=
2296 else
2297         MISC_INSTALL_DATA=install.data
2298         MISC_UNINSTALL_DATA=uninstall.data
2299 fi
2300 AC_SUBST(MISC_INSTALL_DATA)
2301 AC_SUBST(MISC_UNINSTALL_DATA)
2302
2303 SUB_SCRIPTS=
2304
2305 dnl Override the package used for exported symbols
2306 if test -n "$PACKAGE"
2307 then
2308         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2309         export PACKAGE
2310         echo "package: $PACKAGE"
2311 fi
2312
2313 UNALTERED_SYMS=
2314 cf_filter_syms=no
2315
2316 if test -n "$RESULTING_SYMS"
2317 then
2318         cf_filter_syms=$cf_dft_filter_syms
2319         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_version)
2320 fi
2321
2322 if test "x$WILDCARD_SYMS" = xno
2323 then
2324         cf_filter_syms=yes
2325 fi
2326
2327 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2328
2329 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2330 if test $cf_filter_syms = yes
2331 then
2332         RESULTING_SYMS=resulting.map
2333 fi
2334 AC_SUBST(UNALTERED_SYMS)
2335
2336 if test "x$cross_compiling" = xyes ; then
2337         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2338         CHECK_BUILD="#"
2339 else
2340         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2341         CHECK_BUILD=
2342 fi
2343 AC_SUBST(ADAGEN_LDFLAGS)
2344 AC_SUBST(CHECK_BUILD)
2345 AC_SUBST(PRIVATE_LIBS)
2346
2347 AC_DEFINE(HAVE_CURSES_DATA_BOOLNAMES,1,[definition needed for in-tree build of tack])
2348
2349 AC_OUTPUT( \
2350         include/MKterm.h.awk \
2351         include/curses.head:include/curses.h.in \
2352         include/ncurses_dll.h \
2353         include/termcap.h \
2354         include/unctrl.h \
2355         $SUB_SCRIPTS \
2356         $SUB_MAKEFILES \
2357         Makefile,[
2358 if test "x$cf_with_tests" != xno ; then
2359         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2360 fi
2361 CF_LIB_RULES($SRC_SUBDIRS)
2362
2363 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2364 if test -z "$USE_OLD_MAKERULES" ; then
2365         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
2366 fi
2367 fi
2368 ],[
2369 ### Special initialization commands, used to pass information from the
2370 ### configuration-run into config.status
2371
2372 AWK="$AWK"
2373 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2374 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2375 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2376 ECHO_LD="$ECHO_LD"
2377 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2378 LDCONFIG="$LDCONFIG"
2379 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2380 LIB_NAME="$LIB_NAME"
2381 LIB_PREFIX="$LIB_PREFIX"
2382 LIB_SUBSETS="$LIB_SUBSETS"
2383 LIB_SUFFIX="$LIB_SUFFIX"
2384 LIB_TRACING="$LIB_TRACING"
2385 LN_S="$LN_S"
2386 MAKE_TERMINFO="$MAKE_TERMINFO"
2387 NCURSES_MAJOR="$NCURSES_MAJOR"
2388 NCURSES_MINOR="$NCURSES_MINOR"
2389 NCURSES_OSPEED="$NCURSES_OSPEED"
2390 NCURSES_PATCH="$NCURSES_PATCH"
2391 SRC_SUBDIRS="$SRC_SUBDIRS"
2392 TERMINFO="$TERMINFO"
2393 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2394 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2395 TICS_NAME="$TICS_NAME"
2396 TICS_SUFFIX="$TICS_SUFFIX"
2397 TIC_PATH="$TIC_PATH"
2398 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2399 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2400 TINFO_NAME="$TINFO_NAME"
2401 TINFO_SUFFIX="$TINFO_SUFFIX"
2402 UNALTERED_SYMS="$UNALTERED_SYMS"
2403 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2404 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2405 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2406 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2407 WILDCARD_SYMS="$WILDCARD_SYMS"
2408 WITH_CURSES_H="$with_curses_h"
2409 WITH_ECHO="${enable_echo:=yes}"
2410 WITH_OVERWRITE="$with_overwrite"
2411 cf_LIST_MODELS="$cf_list_models"
2412 cf_cv_abi_version="$cf_cv_abi_version"
2413 cf_cv_do_relink="$cf_cv_do_relink"
2414 cf_cv_do_reranlib="$cf_cv_do_reranlib"
2415 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2416 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2417 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2418 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2419 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2420 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2421 cf_cv_rel_version="$cf_cv_rel_version"
2422 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2423 cf_cv_shared_soname='$cf_cv_shared_soname'
2424 cf_cv_shlib_version="$cf_cv_shlib_version"
2425 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2426 cf_cv_system_name="$cf_cv_system_name"
2427 cf_cv_term_driver="$with_term_driver"
2428 cf_with_ada="$cf_with_ada"
2429 cf_with_cxx_binding="$cf_with_cxx_binding"
2430 cf_with_db_install="$cf_with_db_install"
2431 cf_with_manpages="$cf_with_manpages"
2432 cf_with_tests="$cf_with_tests"
2433 host="$host"
2434 target="$target"
2435 with_shared_cxx="$with_shared_cxx"
2436
2437 ],cat)dnl
2438 ${MAKE:-make} preinstall