ncurses 6.1 - patch 20190216
[ncurses.git] / man / manlinks.sed
1 # $Id: manlinks.sed,v 1.13 2008/01/19 23:31:17 tom Exp $
2 ##############################################################################
3 # Copyright (c) 2000-2003,2008 Free Software Foundation, Inc.                #
4 #                                                                            #
5 # Permission is hereby granted, free of charge, to any person obtaining a    #
6 # copy of this software and associated documentation files (the "Software"), #
7 # to deal in the Software without restriction, including without limitation  #
8 # the rights to use, copy, modify, merge, publish, distribute, distribute    #
9 # with modifications, sublicense, and/or sell copies of the Software, and to #
10 # permit persons to whom the Software is furnished to do so, subject to the  #
11 # following conditions:                                                      #
12 #                                                                            #
13 # The above copyright notice and this permission notice shall be included in #
14 # all copies or substantial portions of the Software.                        #
15 #                                                                            #
16 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR #
17 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,   #
18 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL    #
19 # THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER      #
20 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING    #
21 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER        #
22 # DEALINGS IN THE SOFTWARE.                                                  #
23 #                                                                            #
24 # Except as contained in this notice, the name(s) of the above copyright     #
25 # holders shall not be used in advertising or otherwise to promote the sale, #
26 # use or other dealings in this Software without prior written               #
27 # authorization.                                                             #
28 ##############################################################################
29 # Given a manpage (nroff) as input, writes a list of the names that are
30 # listed in the "NAME" section, i.e., the names that we would like to use
31 # as aliases for the manpage -T.Dickey
32 #
33 # eliminate formatting controls that get in the way
34 /^'\\"/d
35 /\.\\"/d
36 /^\.br/d
37 /^\.sp/d
38 /typedef/d
39 s/^\.IX//
40 s/\\f.//g
41 s/[:,]/ /g
42 #
43 # eliminate unnecessary whitespace, convert multiple blanks to single space
44 s/^[    ][      ]*//
45 s/[     ][      ]*$//
46 s/[     ][      ]*/ /g
47 #
48 # convert ".SH" into a more manageable form
49 s/\.SH[         ][      ]*/.SH_(/
50 #
51 # in ".SH NAME"
52 # change "\-" to "-", eliminate text after "-", and split the remaining lines
53 # at each space, making a list of names:
54 /^\.SH_(NAME/,/^\.SH_(SYNOPSIS/{
55 s/\\-.*/ -/
56 / -/{
57 s/ -.*//
58 s/ /\
59 /g
60 }
61 /^-/{
62 d
63 }
64 s/ /\
65 /g
66 }
67 #
68 # in ".SH SYNOPSIS"
69 # remove any line that does not contain a '(', since we only want functions.
70 # then strip off return-type of each function.
71 # finally, remove the parameter list, which begins with a '('.
72 /^\.SH_(SYNOPSIS/,/^\.SH_(DESCRIPTION/{
73 /^[^(]*$/d
74 # reduce
75 #       .B "int add_wch( const cchar_t *\fIwch\fB );"
76 # to
77 #       add_wch( const cchar_t *\fIwch\fB );"
78 s/^\([^ (]* [^ (]* [*]*\)//g
79 s/^\([^ (]* [*]*\)//g
80 # trim blanks in case we have
81 #       void (*) (FORM *) field_init(const FORM *form);
82 s/) (/)(/g
83 # reduce stuff like
84 #       void (*)(FORM *) field_init(const FORM *form);
85 # to
86 #       field_init(const FORM *form);
87 s/^\(([^)]*)\)\(([^)]*)\)*[ ]*//g
88 # rename marker temporarily
89 s/\.SH_(/.SH_/
90 # kill lines with ");", and trim off beginning of argument list.
91 s/[()].*//
92 # rename marker back
93 s/\.SH_/.SH_(/
94 }
95 #
96 # delete ".SH DESCRIPTION" and following lines
97 /^\.SH_(DESCRIPTION/,${
98 d
99 }
100 #
101 # delete any remaining directives
102 /^\./d