mk-1st.awk

   1 # $Id: mk-1st.awk,v 1.95 2013/03/12 11:09:40 tom Exp $
   2 ##############################################################################
   3 # Copyright (c) 1998-2012,2013 Free Software Foundation, Inc.                #
   4 #                                                                            #
   5 # Permission is hereby granted, free of charge, to any person obtaining a    #
   6 # copy of this software and associated documentation files (the "Software"), #
   7 # to deal in the Software without restriction, including without limitation  #
   8 # the rights to use, copy, modify, merge, publish, distribute, distribute    #
   9 # with modifications, sublicense, and/or sell copies of the Software, and to #
  10 # permit persons to whom the Software is furnished to do so, subject to the  #
  11 # following conditions:                                                      #
  12 #                                                                            #
  13 # The above copyright notice and this permission notice shall be included in #
  14 # all copies or substantial portions of the Software.                        #
  15 #                                                                            #
  16 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR #
  17 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,   #
  18 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL    #
  19 # THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER      #
  20 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING    #
  21 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER        #
  22 # DEALINGS IN THE SOFTWARE.                                                  #
  23 #                                                                            #
  24 # Except as contained in this notice, the name(s) of the above copyright     #
  25 # holders shall not be used in advertising or otherwise to promote the sale, #
  26 # use or other dealings in this Software without prior written               #
  27 # authorization.                                                             #
  28 ##############################################################################
  29 #
  30 # Author: Thomas E. Dickey
  31 #
  32 # Generate list of objects for a given model library
  33 # Variables:
  34 #       name              (library name, e.g., "ncurses", "panel", "forms", "menus")
  35 #       traces            ("all" or "DEBUG", to control whether tracing is compiled in)
  36 #       MODEL             (e.g., "DEBUG", uppercase; toupper is not portable)
  37 #       CXX_MODEL         (e.g., "DEBUG", uppercase)
  38 #       model             (directory into which we compile, e.g., "obj")
  39 #       prefix            (e.g., "lib", for Unix-style libraries)
  40 #       suffix            (e.g., "_g.a", for debug libraries)
  41 #       subset            ("none", "base", "base+ext_funcs" or "termlib", etc.)
  42 #       driver            ("yes" or "no", depends on --enable-term-driver)
  43 #       ShlibVer          ("rel", "abi" or "auto", to augment DoLinks variable)
  44 #       ShlibVerInfix ("yes" or "no", determines location of version #)
  45 #       SymLink           ("ln -s", etc)
  46 #       TermlibRoot       ("tinfo" or other root for libterm.so)
  47 #       TermlibSuffix (".so" or other suffix for libterm.so)
  48 #       ReLink            ("yes", or "no", flag to rebuild shared libs on install)
  49 #       DoLinks           ("yes", "reverse" or "no", flag to add symbolic links)
  50 #       rmSoLocs          ("yes" or "no", flag to add extra clean target)
  51 #       ldconfig          (path for this tool, if used)
  52 #       overwrite         ("yes" or "no", flag to add link to libcurses.a
  53 #       depend            (optional dependencies for all objects, e.g, ncurses_cfg.h)
  54 #       host              (cross-compile host, if any)
  55 #       libtool_version (libtool "-version-info" or "-version-number")
  56 #
  57 # Notes:
  58 #       CLIXs nawk does not like underscores in command-line variable names.
  59 #       Mixed-case variable names are ok.
  60 #       HP/UX requires shared libraries to have executable permissions.
  61 #
  62 function is_ticlib() {
  63                 return ( subset ~ /^ticlib$/ );
  64         }
  65 function is_termlib() {
  66                 return ( subset ~ /^(ticlib\+)?termlib((\+[^+ ]+)*\+[a-z_]+_tinfo)?$/ );
  67         }
  68 # see lib_name
  69 function lib_name_of(a_name) {
  70                 return sprintf("%s%s%s", prefix, a_name, suffix)
  71         }
  72 # see imp_name
  73 function imp_name_of(a_name) {
  74                 if (ShlibVerInfix == "cygdll" || ShlibVerInfix == "mingw") {
  75                         result = sprintf("%s%s%s.a", prefix, a_name, suffix);
  76                 } else {
  77                         result = "";
  78                 }
  79                 return result;
  80         }
  81 # see abi_name
  82 function abi_name_of(a_name) {
  83                 if (ShlibVerInfix == "cygdll") {
  84                         result = sprintf("%s%s$(ABI_VERSION)%s", "cyg", a_name, suffix);
  85                 } else if (ShlibVerInfix == "mingw") {
  86                         result = sprintf("%s%s$(ABI_VERSION)%s", prefix, a_name, suffix);
  87                 } else if (ShlibVerInfix == "yes") {
  88                         result = sprintf("%s%s.$(ABI_VERSION)%s", prefix, a_name, suffix);
  89                 } else {
  90                         result = sprintf("%s.$(ABI_VERSION)", lib_name_of(a_name));
  91                 }
  92                 return result;
  93         }
  94 # see rel_name
  95 function rel_name_of(a_name) {
  96                 if (ShlibVerInfix == "cygdll") {
  97                         result = sprintf("%s%s$(REL_VERSION)%s", "cyg", a_name, suffix);
  98                 } else if (ShlibVerInfix == "mingw") {
  99                         result = sprintf("%s%s$(REL_VERSION)%s", prefix, a_name, suffix);
 100                 } else if (ShlibVerInfix == "yes") {
 101                         result = sprintf("%s%s.$(REL_VERSION)%s", prefix, a_name, suffix);
 102                 } else {
 103                         result = sprintf("%s.$(REL_VERSION)", lib_name_of(a_name));
 104                 }
 105                 return result;
 106         }
 107 # see end_name
 108 function end_name_of(a_name) {
 109                 if ( MODEL != "SHARED" ) {
 110                         result = lib_name_of(a_name);
 111                 } else if ( DoLinks == "reverse") {
 112                         result = lib_name_of(a_name);
 113                 } else {
 114                         if ( ShlibVer == "rel" ) {
 115                                 result = rel_name_of(a_name);
 116                         } else if ( ShlibVer == "abi" || ShlibVer == "cygdll" || ShlibVer == "mingw" ) {
 117                                 result = abi_name_of(a_name);
 118                         } else {
 119                                 result = lib_name_of(a_name);
 120                         }
 121                 }
 122                 return result
 123         }
 124 function symlink(src,dst) {
 125                 if ( src != dst ) {
 126                         if ( SymLink !~ /.*-f.*/ ) {
 127                                 printf "rm -f %s; ", dst
 128                         }
 129                         printf "$(LN_S) %s %s; ", src, dst
 130                 }
 131         }
 132 function rmlink(directory, dst) {
 133                 if ( dst != "" ) {
 134                         printf "\t-rm -f %s/%s\n", directory, dst
 135                 }
 136         }
 137 function removelinks(directory) {
 138                 nlinks = 0;
 139                 links[nlinks++] = end_name;
 140                 if ( DoLinks == "reverse" ) {
 141                         if ( ShlibVer == "rel" ) {
 142                                 links[nlinks++] = abi_name;
 143                                 links[nlinks++] = rel_name;
 144                         } else if ( ShlibVer == "abi" ) {
 145                                 links[nlinks++] = abi_name;
 146                         }
 147                 } else {
 148                         if ( ShlibVer == "rel" ) {
 149                                 links[nlinks++] = abi_name;
 150                                 links[nlinks++] = lib_name;
 151                         } else if ( ShlibVer == "abi" ) {
 152                                 links[nlinks++] = lib_name;
 153                         }
 154                 }
 155                 for (j = 0; j < nlinks; ++j) {
 156                         found = 0;
 157                         for (k = 0; k < j; ++k ) {
 158                                 if ( links[j] == links[k] ) {
 159                                         found = 1;
 160                                         break;
 161                                 }
 162                         }
 163                         if ( !found ) {
 164                                 rmlink(directory, links[j]);
 165                         }
 166                 }
 167         }
 168 function make_shlib(objs, shlib_list) {
 169                 printf "\t$(MK_SHARED_LIB) $(%s_OBJS) $(%s) $(LDFLAGS)\n", objs, shlib_list
 170         }
 171 function sharedlinks(directory) {
 172                 if ( ShlibVer != "auto" && ShlibVer != "cygdll" && ShlibVer != "mingw" ) {
 173                         printf "\tcd %s && (", directory
 174                         if ( DoLinks == "reverse" ) {
 175                                 if ( ShlibVer == "rel" ) {
 176                                         symlink(lib_name, abi_name);
 177                                         symlink(abi_name, rel_name);
 178                                 } else if ( ShlibVer == "abi" ) {
 179                                         symlink(lib_name, abi_name);
 180                                 }
 181                         } else {
 182                                 if ( ShlibVer == "rel" ) {
 183                                         symlink(rel_name, abi_name);
 184                                         symlink(abi_name, lib_name);
 185                                 } else if ( ShlibVer == "abi" ) {
 186                                         symlink(abi_name, lib_name);
 187                                 }
 188                         }
 189                         printf ")\n"
 190                 }
 191         }
 192 # termlib may be named explicitly via "--with-termlib=XXX", which overrides
 193 # any suffix.  Temporarily override "suffix" to account for this.
 194 function termlib_end_of() {
 195         termlib_save_suffix = suffix;
 196         suffix = TermlibSuffix;
 197         termlib_temp_result = end_name_of(TermlibRoot);
 198         suffix = termlib_save_suffix;
 199         return termlib_temp_result;
 200 }
 201 function shlib_build(directory) {
 202                 dst_libs = sprintf("%s/%s", directory, end_name);
 203                 printf "%s : \\\n", dst_libs
 204                 printf "\t\t%s \\\n", directory
 205                 if (subset == "ticlib" && driver == "yes" ) {
 206                         base = name;
 207                         sub(/^tic/, "ncurses", base); # workaround for "w"
 208                         printf "\t\t%s/%s \\\n", directory, end_name_of(base);
 209                 }
 210                 if (subset ~ /^base/ || subset == "ticlib" ) {
 211                         save_suffix = suffix
 212                         sub(/^[^.]\./,".",suffix)
 213                         if (directory != "../lib") {
 214                                 printf "\t\t%s/%s \\\n", "../lib", termlib_end_of();
 215                         }
 216                         printf "\t\t%s/%s \\\n", directory, termlib_end_of();
 217                         suffix = save_suffix
 218                 }
 219                 printf "\t\t$(%s_OBJS)\n", OBJS
 220                 printf "\t@echo linking $@\n"
 221                 if ( is_ticlib() ) {
 222                         make_shlib(OBJS, "TICS_LIST")
 223                 } else if ( is_termlib() ) {
 224                         make_shlib(OBJS, "TINFO_LIST")
 225                 } else {
 226                         make_shlib(OBJS, "SHLIB_LIST")
 227                 }
 228                 sharedlinks(directory)
 229         }
 230 function shlib_install(directory) {
 231                 src_lib1 = sprintf("../lib/%s", end_name);
 232                 dst_lib1 = sprintf("%s/%s", directory, end_name);
 233                 printf "%s : \\\n", dst_lib1
 234                 printf "\t\t%s \\\n", directory
 235                 printf "\t\t%s\n", src_lib1
 236                 printf "\t@echo installing $@\n"
 237                 printf "\t$(INSTALL_LIB) %s %s\n", src_lib1, dst_lib1;
 238                 sharedlinks(directory)
 239         }
 240 function install_dll(directory,filename) {
 241                 src_name = sprintf("../lib/%s", filename);
 242                 dst_name = sprintf("$(DESTDIR)%s/%s", directory, filename);
 243                 printf "\t@echo installing %s as %s\n", src_name, dst_name
 244                 if ( directory == "$(bindir)" ) {
 245                         program = "$(INSTALL) -m 755";
 246                 } else {
 247                         program = "$(INSTALL_LIB)";
 248                 }
 249                 printf "\t%s %s %s\n", program, src_name, dst_name
 250         }
 251 BEGIN   {
 252                 TOOL_PREFIX = "";
 253                 found = 0;
 254                 using = 0;
 255         }
 256         /^@/ {
 257                 using = 0
 258                 if (subset == "none") {
 259                         using = 1
 260                 } else if (index(subset,$2) > 0) {
 261                         if (using == 0) {
 262                                 if (found == 0) {
 263                                         if ( name ~ /^.*\+\+.*/ ) {
 264                                                 if ( CXX_MODEL == "NORMAL" && MODEL == "SHARED" ) {
 265                                                         print  ""
 266                                                         printf "# overriding model from %s to match CXX_MODEL\n", MODEL;
 267                                                         MODEL = "NORMAL";
 268                                                         suffix = ".a";
 269                                                         DoLinks = "no";
 270                                                 }
 271                                         }
 272                                         print  ""
 273                                         printf "# generated by mk-1st.awk (subset=%s)\n", subset
 274                                         printf "#  name:          %s\n", name
 275                                         printf "#  traces:        %s\n", traces
 276                                         printf "#  MODEL:         %s\n", MODEL
 277                                         printf "#  CXX_MODEL:     %s\n", CXX_MODEL
 278                                         printf "#  model:         %s\n", model
 279                                         printf "#  prefix:        %s\n", prefix
 280                                         printf "#  suffix:        %s\n", suffix
 281                                         printf "#  subset:        %s\n", subset
 282                                         printf "#  driver:        %s\n", driver
 283                                         printf "#  ShlibVer:      %s\n", ShlibVer
 284                                         printf "#  ShlibVerInfix: %s\n", ShlibVerInfix
 285                                         printf "#  SymLink:       %s\n", SymLink
 286                                         printf "#  TermlibRoot:   %s\n", TermlibRoot
 287                                         printf "#  TermlibSuffix: %s\n", TermlibSuffix
 288                                         printf "#  ReLink:        %s\n", ReLink
 289                                         printf "#  DoLinks:       %s\n", DoLinks
 290                                         printf "#  rmSoLocs:      %s\n", rmSoLocs
 291                                         printf "#  ldconfig:      %s\n", ldconfig
 292                                         printf "#  overwrite:     %s\n", overwrite
 293                                         printf "#  depend:        %s\n", depend
 294                                         printf "#  host:          %s\n", host
 295                                         print  ""
 296                                 }
 297                                 using = 1
 298                         }
 299                         if ( is_ticlib() ) {
 300                                 OBJS  = MODEL "_P"
 301                         } else if ( is_termlib() ) {
 302                                 OBJS  = MODEL "_T"
 303                         } else {
 304                                 OBJS  = MODEL
 305                         }
 306                 }
 307         }
 308         /^[@#]/ {
 309                 next
 310         }
 311         $1 ~ /trace/ {
 312                 if (traces != "all" && traces != MODEL && $1 != "lib_trace")
 313                         next
 314         }
 315         {
 316                 if (using \
 317                  && ( $1 != "link_test" ) \
 318                  && ( $2 == "lib" \
 319                    || $2 == "progs" \
 320                    || $2 == "c++" \
 321                    || $2 == "tack" ))
 322                 {
 323                         if ( found == 0 )
 324                         {
 325                                 printf "%s_OBJS =", OBJS
 326                                 if ( $2 == "lib" ) {
 327                                         found = 1;
 328                                 } else if ( $2 == "c++" ) {
 329                                         TOOL_PREFIX = "CXX_";
 330                                         found = 1;
 331                                 } else {
 332                                         found = 2;
 333                                 }
 334                                 if ( $2 == "c++" ) {
 335                                         CC_NAME="CXX"
 336                                         CC_FLAG="CXXFLAGS"
 337                                 } else {
 338                                         CC_NAME="CC"
 339                                         CC_FLAG="CFLAGS"
 340                                 }
 341                         }
 342                         printf " \\\n\t../%s/%s$o", model, $1;
 343                 }
 344         }
 345 END     {
 346                 print  ""
 347                 if ( found != 0 )
 348                 {
 349                         printf "\n$(%s_OBJS) : %s\n", OBJS, depend
 350                 }
 351                 if ( found == 1 )
 352                 {
 353                         print  ""
 354                         lib_name = lib_name_of(name);
 355                         if ( MODEL == "SHARED" )
 356                         {
 357                                 abi_name = abi_name_of(name);
 358                                 rel_name = rel_name_of(name);
 359                                 imp_name = imp_name_of(name);
 360                                 end_name = end_name_of(name);
 361
 362                                 shlib_build("../lib")
 363
 364                                 print  ""
 365                                 print  "install \\"
 366                                 print  "install.libs \\"
 367
 368                                 if ( ShlibVer == "cygdll" || ShlibVer == "mingw") {
 369
 370                                         dst_dirs = "$(DESTDIR)$(bindir) $(DESTDIR)$(libdir)";
 371                                         printf "install.%s :: %s $(LIBRARIES)\n", name, dst_dirs
 372                                         install_dll("$(bindir)",end_name);
 373                                         install_dll("$(libdir)",imp_name);
 374
 375                                 } else {
 376
 377                                         lib_dir = "$(DESTDIR)$(libdir)";
 378                                         printf "install.%s :: %s/%s\n", name, lib_dir, end_name
 379                                         print ""
 380                                         if ( ReLink == "yes" ) {
 381                                                 shlib_build(lib_dir)
 382                                         } else {
 383                                                 shlib_install(lib_dir)
 384                                         }
 385                                 }
 386
 387                                 if ( overwrite == "yes" && name == "ncurses" )
 388                                 {
 389                                         if ( ShlibVer == "cygdll" || ShlibVer == "mingw") {
 390                                                 ovr_name = sprintf("libcurses%s.a", suffix)
 391                                                 printf "\t@echo linking %s to %s\n", imp_name, ovr_name
 392                                                 printf "\tcd $(DESTDIR)$(libdir) && ("
 393                                                 symlink(imp_name, ovr_name)
 394                                                 printf ")\n"
 395                                         } else {
 396                                                 ovr_name = sprintf("libcurses%s", suffix)
 397                                                 printf "\t@echo linking %s to %s\n", end_name, ovr_name
 398                                                 printf "\tcd $(DESTDIR)$(libdir) && ("
 399                                                 symlink(end_name, ovr_name)
 400                                                 printf ")\n"
 401                                         }
 402                                 }
 403                                 if ( ldconfig != "" && ldconfig != ":" ) {
 404                                         printf "\t- test -z \"$(DESTDIR)\" && %s\n", ldconfig
 405                                 }
 406                                 print  ""
 407                                 print  "uninstall \\"
 408                                 print  "uninstall.libs \\"
 409                                 printf "uninstall.%s ::\n", name
 410                                 if ( ShlibVer == "cygdll" || ShlibVer == "mingw") {
 411
 412                                         printf "\t@echo uninstalling $(DESTDIR)$(bindir)/%s\n", end_name
 413                                         printf "\t-@rm -f $(DESTDIR)$(bindir)/%s\n", end_name
 414
 415                                         printf "\t@echo uninstalling $(DESTDIR)$(libdir)/%s\n", imp_name
 416                                         printf "\t-@rm -f $(DESTDIR)$(libdir)/%s\n", imp_name
 417
 418                                 } else {
 419                                         printf "\t@echo uninstalling $(DESTDIR)$(libdir)/%s\n", end_name
 420                                         removelinks("$(DESTDIR)$(libdir)")
 421                                         if ( overwrite == "yes" && name == "ncurses" )
 422                                         {
 423                                                 ovr_name = sprintf("libcurses%s", suffix)
 424                                                 printf "\t-@rm -f $(DESTDIR)$(libdir)/%s\n", ovr_name
 425                                         }
 426                                 }
 427                                 if ( rmSoLocs == "yes" ) {
 428                                         print  ""
 429                                         print  "mostlyclean \\"
 430                                         print  "clean ::"
 431                                         printf "\t-@rm -f so_locations\n"
 432                                 }
 433                         }
 434                         else if ( MODEL == "LIBTOOL" )
 435                         {
 436                                 end_name = lib_name;
 437                                 printf "../lib/%s : $(%s_OBJS)\n", lib_name, OBJS
 438                                 if ( is_ticlib() ) {
 439                                         which_list = "TICS_LIST";
 440                                 } else if ( is_termlib() ) {
 441                                         which_list = "TINFO_LIST";
 442                                 } else {
 443                                         which_list = "SHLIB_LIST";
 444                                 }
 445                                 printf "\tcd ../lib && $(LIBTOOL_LINK) $(%s) $(%s) \\\n", CC_NAME, CC_FLAG;
 446                                 printf "\t\t-o %s $(%s_OBJS:$o=.lo) \\\n", lib_name, OBJS;
 447                                 printf "\t\t-rpath $(DESTDIR)$(libdir) \\\n";
 448                                 printf "\t\t%s $(NCURSES_MAJOR):$(NCURSES_MINOR) $(LT_UNDEF) $(%s) $(LDFLAGS)\n", libtool_version, which_list;
 449                                 print  ""
 450                                 print  "install \\"
 451                                 print  "install.libs \\"
 452                                 printf "install.%s :: $(DESTDIR)$(libdir) ../lib/%s\n", name, lib_name
 453                                 printf "\t@echo installing ../lib/%s as $(DESTDIR)$(libdir)/%s\n", lib_name, lib_name
 454                                 printf "\tcd ../lib; $(LIBTOOL_INSTALL) $(INSTALL) %s $(DESTDIR)$(libdir)\n", lib_name
 455                                 print  ""
 456                                 print  "uninstall \\"
 457                                 print  "uninstall.libs \\"
 458                                 printf "uninstall.%s ::\n", name
 459                                 printf "\t@echo uninstalling $(DESTDIR)$(libdir)/%s\n", lib_name
 460                                 printf "\t-@$(LIBTOOL_UNINSTALL) rm -f $(DESTDIR)$(libdir)/%s\n", lib_name
 461                         }
 462                         else
 463                         {
 464                                 end_name = lib_name;
 465                                 printf "../lib/%s : $(%s_OBJS)\n", lib_name, OBJS
 466                                 printf "\t$(%sAR) $(%sARFLAGS) $@ $?\n", TOOL_PREFIX, TOOL_PREFIX;
 467                                 printf "\t$(RANLIB) $@\n"
 468                                 if ( host == "vxworks" )
 469                                 {
 470                                         printf "\t$(LD) $(LD_OPTS) $? -o $(@:.a=$o)\n"
 471                                 }
 472                                 print  ""
 473                                 print  "install \\"
 474                                 print  "install.libs \\"
 475                                 printf "install.%s :: $(DESTDIR)$(libdir) ../lib/%s\n", name, lib_name
 476                                 printf "\t@echo installing ../lib/%s as $(DESTDIR)$(libdir)/%s\n", lib_name, lib_name
 477                                 printf "\t$(INSTALL_DATA) ../lib/%s $(DESTDIR)$(libdir)/%s\n", lib_name, lib_name
 478                                 if ( overwrite == "yes" && lib_name == "libncurses.a" )
 479                                 {
 480                                         printf "\t@echo linking libcurses.a to libncurses.a\n"
 481                                         printf "\t-@rm -f $(DESTDIR)$(libdir)/libcurses.a\n"
 482                                         printf "\t(cd $(DESTDIR)$(libdir) && "
 483                                         symlink("libncurses.a", "libcurses.a")
 484                                         printf ")\n"
 485                                 }
 486                                 printf "\t$(RANLIB) $(DESTDIR)$(libdir)/%s\n", lib_name
 487                                 if ( host == "vxworks" )
 488                                 {
 489                                         printf "\t@echo installing ../lib/lib%s$o as $(DESTDIR)$(libdir)/lib%s$o\n", name, name
 490                                         printf "\t$(INSTALL_DATA) ../lib/lib%s$o $(DESTDIR)$(libdir)/lib%s$o\n", name, name
 491                                 }
 492                                 print  ""
 493                                 print  "uninstall \\"
 494                                 print  "uninstall.libs \\"
 495                                 printf "uninstall.%s ::\n", name
 496                                 printf "\t@echo uninstalling $(DESTDIR)$(libdir)/%s\n", lib_name
 497                                 printf "\t-@rm -f $(DESTDIR)$(libdir)/%s\n", lib_name
 498                                 if ( overwrite == "yes" && lib_name == "libncurses.a" )
 499                                 {
 500                                         printf "\t@echo linking libcurses.a to libncurses.a\n"
 501                                         printf "\t-@rm -f $(DESTDIR)$(libdir)/libcurses.a\n"
 502                                 }
 503                                 if ( host == "vxworks" )
 504                                 {
 505                                         printf "\t@echo uninstalling $(DESTDIR)$(libdir)/lib%s$o\n", name
 506                                         printf "\t-@rm -f $(DESTDIR)$(libdir)/lib%s$o\n", name
 507                                 }
 508                         }
 509                         print ""
 510                         print "clean ::"
 511                         removelinks("../lib");
 512                         print ""
 513                         print "mostlyclean::"
 514                         printf "\t-rm -f $(%s_OBJS)\n", OBJS
 515                         if ( MODEL == "LIBTOOL" ) {
 516                                 printf "\t-$(LIBTOOL_CLEAN) rm -f $(%s_OBJS:$o=.lo)\n", OBJS
 517                         }
 518                 }
 519                 else if ( found == 2 )
 520                 {
 521                         print ""
 522                         print "mostlyclean::"
 523                         printf "\t-rm -f $(%s_OBJS)\n", OBJS
 524                         if ( MODEL == "LIBTOOL" ) {
 525                                 printf "\t-$(LIBTOOL_CLEAN) rm -f $(%s_OBJS:$o=.lo)\n", OBJS
 526                         }
 527                         print ""
 528                         print "clean ::"
 529                         printf "\t-rm -f $(%s_OBJS)\n", OBJS
 530                         if ( MODEL == "LIBTOOL" ) {
 531                                 printf "\t-$(LIBTOOL_CLEAN) rm -f $(%s_OBJS:$o=.lo)\n", OBJS
 532                         }
 533                 }
 534         }
 535 # vile:ts=4 sw=4