test/aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2019,2020 Thomas E. Dickey                                *
   3 dnl Copyright 2003-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl $Id: aclocal.m4,v 1.184 2020/10/31 20:05:07 tom Exp $
  31 dnl
  32 dnl Author: Thomas E. Dickey
  33 dnl
  34 dnl Macros used in NCURSES test programs auto-configuration script.
  35 dnl
  36 dnl These macros are maintained separately from NCURSES.  The copyright on
  37 dnl this file applies to the aggregation of macros and does not affect use of
  38 dnl these macros in other applications.
  39 dnl
  40 dnl See these pages for additional information:
  41 dnl             https://invisible-island.net/autoconf/
  42 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  43 dnl
  44 dnl ---------------------------------------------------------------------------
  45 dnl ---------------------------------------------------------------------------
  46 dnl AM_LANGINFO_CODESET version: 5 updated: 2020/03/10 18:53:47
  47 dnl -------------------
  48 dnl Inserted as requested by gettext 0.10.40
  49 dnl File from /usr/share/aclocal
  50 dnl codeset.m4
  51 dnl ====================
  52 dnl serial AM1
  53 dnl
  54 dnl From Bruno Haible.
  55 AC_DEFUN([AM_LANGINFO_CODESET],
  56 [
  57 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  58         [AC_TRY_LINK([#include <langinfo.h>],
  59         [char* cs = nl_langinfo(CODESET); (void)cs],
  60         am_cv_langinfo_codeset=yes,
  61         am_cv_langinfo_codeset=no)
  62         ])
  63         if test $am_cv_langinfo_codeset = yes; then
  64                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  65                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  66         fi
  67 ])dnl
  68 dnl ---------------------------------------------------------------------------
  69 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
  70 dnl ------------------
  71 dnl Conditionally generate script according to whether we're using a given autoconf.
  72 dnl
  73 dnl $1 = version to compare against
  74 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  75 dnl $3 = code to use if AC_ACVERSION is older than $1.
  76 define([CF_ACVERSION_CHECK],
  77 [
  78 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
  79 ifdef([m4_version_compare],
  80 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  81 [CF_ACVERSION_COMPARE(
  82 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  83 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  84 dnl ---------------------------------------------------------------------------
  85 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  86 dnl --------------------
  87 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  88 dnl                      MAJOR2, MINOR2, TERNARY2,
  89 dnl                      PRINTABLE2, not FOUND, FOUND)
  90 define([CF_ACVERSION_COMPARE],
  91 [ifelse(builtin([eval], [$2 < $5]), 1,
  92 [ifelse([$8], , ,[$8])],
  93 [ifelse([$9], , ,[$9])])])dnl
  94 dnl ---------------------------------------------------------------------------
  95 dnl CF_ADD_CFLAGS version: 14 updated: 2020/04/04 16:16:13
  96 dnl -------------
  97 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
  98 dnl $1 = flags to add
  99 dnl $2 = if given makes this macro verbose.
 100 dnl
 101 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 102 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 103 dnl confused by the quotes (which require backslashes to keep them usable).
 104 AC_DEFUN([CF_ADD_CFLAGS],
 105 [
 106 cf_fix_cppflags=no
 107 cf_new_cflags=
 108 cf_new_cppflags=
 109 cf_new_extra_cppflags=
 110
 111 for cf_add_cflags in $1
 112 do
 113 case $cf_fix_cppflags in
 114 (no)
 115         case $cf_add_cflags in
 116         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 117                 case $cf_add_cflags in
 118                 (-D*)
 119                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 120
 121                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 122                                 && test -z "${cf_tst_cflags}" \
 123                                 && cf_fix_cppflags=yes
 124
 125                         if test $cf_fix_cppflags = yes ; then
 126                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 127                                 continue
 128                         elif test "${cf_tst_cflags}" = "\"'" ; then
 129                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 130                                 continue
 131                         fi
 132                         ;;
 133                 esac
 134                 case "$CPPFLAGS" in
 135                 (*$cf_add_cflags)
 136                         ;;
 137                 (*)
 138                         case $cf_add_cflags in
 139                         (-D*)
 140                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 141                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 142                                 ;;
 143                         esac
 144                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 145                         ;;
 146                 esac
 147                 ;;
 148         (*)
 149                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 150                 ;;
 151         esac
 152         ;;
 153 (yes)
 154         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 155
 156         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 157
 158         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 159                 && test -z "${cf_tst_cflags}" \
 160                 && cf_fix_cppflags=no
 161         ;;
 162 esac
 163 done
 164
 165 if test -n "$cf_new_cflags" ; then
 166         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 167         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 168 fi
 169
 170 if test -n "$cf_new_cppflags" ; then
 171         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 172         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 173 fi
 174
 175 if test -n "$cf_new_extra_cppflags" ; then
 176         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 177         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 178 fi
 179
 180 AC_SUBST(EXTRA_CPPFLAGS)
 181
 182 ])dnl
 183 dnl ---------------------------------------------------------------------------
 184 dnl CF_ADD_INCDIR version: 15 updated: 2018/06/20 20:23:13
 185 dnl -------------
 186 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 187 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 188 dnl but old versions (and some misinstalled ones) need that.  To make things
 189 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 190 dnl the include-path).
 191 AC_DEFUN([CF_ADD_INCDIR],
 192 [
 193 if test -n "$1" ; then
 194   for cf_add_incdir in $1
 195   do
 196         while test $cf_add_incdir != /usr/include
 197         do
 198           if test -d $cf_add_incdir
 199           then
 200                 cf_have_incdir=no
 201                 if test -n "$CFLAGS$CPPFLAGS" ; then
 202                   # a loop is needed to ensure we can add subdirs of existing dirs
 203                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 204                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 205                           cf_have_incdir=yes; break
 206                         fi
 207                   done
 208                 fi
 209
 210                 if test "$cf_have_incdir" = no ; then
 211                   if test "$cf_add_incdir" = /usr/local/include ; then
 212                         if test "$GCC" = yes
 213                         then
 214                           cf_save_CPPFLAGS=$CPPFLAGS
 215                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 216                           AC_TRY_COMPILE([#include <stdio.h>],
 217                                   [printf("Hello")],
 218                                   [],
 219                                   [cf_have_incdir=yes])
 220                           CPPFLAGS=$cf_save_CPPFLAGS
 221                         fi
 222                   fi
 223                 fi
 224
 225                 if test "$cf_have_incdir" = no ; then
 226                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 227                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 228
 229                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 230                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 231                   cf_add_incdir="$cf_top_incdir"
 232                 else
 233                   break
 234                 fi
 235           else
 236                 break
 237           fi
 238         done
 239   done
 240 fi
 241 ])dnl
 242 dnl ---------------------------------------------------------------------------
 243 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 244 dnl ----------
 245 dnl Add a library, used to enforce consistency.
 246 dnl
 247 dnl $1 = library to add, without the "-l"
 248 dnl $2 = variable to update (default $LIBS)
 249 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 250 dnl ---------------------------------------------------------------------------
 251 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 252 dnl -------------
 253 dnl     Adds to the library-path
 254 dnl
 255 dnl     Some machines have trouble with multiple -L options.
 256 dnl
 257 dnl $1 is the (list of) directory(s) to add
 258 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 259 dnl
 260 AC_DEFUN([CF_ADD_LIBDIR],
 261 [
 262 if test -n "$1" ; then
 263         for cf_add_libdir in $1
 264         do
 265                 if test $cf_add_libdir = /usr/lib ; then
 266                         :
 267                 elif test -d $cf_add_libdir
 268                 then
 269                         cf_have_libdir=no
 270                         if test -n "$LDFLAGS$LIBS" ; then
 271                                 # a loop is needed to ensure we can add subdirs of existing dirs
 272                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 273                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 274                                                 cf_have_libdir=yes; break
 275                                         fi
 276                                 done
 277                         fi
 278                         if test "$cf_have_libdir" = no ; then
 279                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 280                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 281                         fi
 282                 fi
 283         done
 284 fi
 285 ])dnl
 286 dnl ---------------------------------------------------------------------------
 287 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
 288 dnl -----------
 289 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 290 dnl prepended to an existing list, since their dependencies are assumed to
 291 dnl already exist in the list.
 292 dnl
 293 dnl $1 = libraries to add, with the "-l", etc.
 294 dnl $2 = variable to update (default $LIBS)
 295 AC_DEFUN([CF_ADD_LIBS],[
 296 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
 297 # reverse order
 298 cf_add_0lib=
 299 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
 300 # filter duplicates
 301 for cf_add_1lib in $cf_add_0lib; do
 302         for cf_add_2lib in $cf_add_libs; do
 303                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
 304                         cf_add_1lib=
 305                         break
 306                 fi
 307         done
 308         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
 309 done
 310 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 311 ])dnl
 312 dnl ---------------------------------------------------------------------------
 313 dnl CF_ADD_LIB_AFTER version: 3 updated: 2013/07/09 21:27:22
 314 dnl ----------------
 315 dnl Add a given library after another, e.g., following the one it satisfies a
 316 dnl dependency for.
 317 dnl
 318 dnl $1 = the first library
 319 dnl $2 = its dependency
 320 AC_DEFUN([CF_ADD_LIB_AFTER],[
 321 CF_VERBOSE(...before $LIBS)
 322 LIBS=`echo "$LIBS" | sed -e "s/[[       ]][[    ]]*/ /g" -e "s%$1 %$1 $2 %" -e 's%  % %g'`
 323 CF_VERBOSE(...after  $LIBS)
 324 ])dnl
 325 dnl ---------------------------------------------------------------------------
 326 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 327 dnl ------------------
 328 dnl Append to a search-list for a nonstandard header/lib-file
 329 dnl     $1 = the variable to return as result
 330 dnl     $2 = the package name
 331 dnl     $3 = the subdirectory, e.g., bin, include or lib
 332 dnl $4 = the directory under which we will test for subdirectories
 333 dnl $5 = a directory that we do not want $4 to match
 334 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 335 [
 336 test "x$4" != "x$5" && \
 337 test -d "$4" && \
 338 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 339         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 340         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 341         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 342         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 343         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 344         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 345 }
 346 ])dnl
 347 dnl ---------------------------------------------------------------------------
 348 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 349 dnl --------------
 350 dnl use this macro for appending text without introducing an extra blank at
 351 dnl the beginning
 352 define([CF_APPEND_TEXT],
 353 [
 354         test -n "[$]$1" && $1="[$]$1 "
 355         $1="[$]{$1}$2"
 356 ])dnl
 357 dnl ---------------------------------------------------------------------------
 358 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 359 dnl --------------
 360 dnl Allow user to disable a normally-on option.
 361 AC_DEFUN([CF_ARG_DISABLE],
 362 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 363 dnl ---------------------------------------------------------------------------
 364 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 365 dnl -------------
 366 dnl Allow user to enable a normally-off option.
 367 AC_DEFUN([CF_ARG_ENABLE],
 368 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 369 dnl ---------------------------------------------------------------------------
 370 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 371 dnl -------------
 372 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 373 dnl values.
 374 dnl
 375 dnl Parameters:
 376 dnl $1 = option name
 377 dnl $2 = help-string
 378 dnl $3 = action to perform if option is not default
 379 dnl $4 = action if perform if option is default
 380 dnl $5 = default option value (either 'yes' or 'no')
 381 AC_DEFUN([CF_ARG_OPTION],
 382 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 383         if test "$enableval" != "$5" ; then
 384 ifelse([$3],,[    :]dnl
 385 ,[    $3]) ifelse([$4],,,[
 386         else
 387                 $4])
 388         fi],[enableval=$5 ifelse([$4],,,[
 389         $4
 390 ])dnl
 391 ])])dnl
 392 dnl ---------------------------------------------------------------------------
 393 dnl CF_CC_ENV_FLAGS version: 9 updated: 2018/07/29 18:03:26
 394 dnl ---------------
 395 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 396 dnl into CC.  This will not help with broken scripts that wrap the compiler
 397 dnl with options, but eliminates a more common category of user confusion.
 398 dnl
 399 dnl In particular, it addresses the problem of being able to run the C
 400 dnl preprocessor in a consistent manner.
 401 dnl
 402 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 403 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 404 dnl outweighs that limitation.
 405 AC_DEFUN([CF_CC_ENV_FLAGS],
 406 [
 407 # This should have been defined by AC_PROG_CC
 408 : ${CC:=cc}
 409
 410 AC_MSG_CHECKING(\$CFLAGS variable)
 411 case "x$CFLAGS" in
 412 (*-[[IUD]]*)
 413         AC_MSG_RESULT(broken)
 414         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 415         cf_flags="$CFLAGS"
 416         CFLAGS=
 417         for cf_arg in $cf_flags
 418         do
 419                 CF_ADD_CFLAGS($cf_arg)
 420         done
 421         ;;
 422 (*)
 423         AC_MSG_RESULT(ok)
 424         ;;
 425 esac
 426
 427 AC_MSG_CHECKING(\$CC variable)
 428 case "$CC" in
 429 (*[[\ \ ]]-*)
 430         AC_MSG_RESULT(broken)
 431         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 432         # humor him...
 433         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 434         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 435         CC="$cf_prog"
 436         for cf_arg in $cf_flags
 437         do
 438                 case "x$cf_arg" in
 439                 (x-[[IUDfgOW]]*)
 440                         CF_ADD_CFLAGS($cf_arg)
 441                         ;;
 442                 (*)
 443                         CC="$CC $cf_arg"
 444                         ;;
 445                 esac
 446         done
 447         CF_VERBOSE(resulting CC: '$CC')
 448         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 449         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 450         ;;
 451 (*)
 452         AC_MSG_RESULT(ok)
 453         ;;
 454 esac
 455 ])dnl
 456 dnl ---------------------------------------------------------------------------
 457 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 458 dnl --------------
 459 dnl Check if we're accidentally using a cache from a different machine.
 460 dnl Derive the system name, as a check for reusing the autoconf cache.
 461 dnl
 462 dnl If we've packaged config.guess and config.sub, run that (since it does a
 463 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 464 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 465 dnl which is useful in cross-compiles.
 466 dnl
 467 dnl Note: we would use $ac_config_sub, but that is one of the places where
 468 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 469 AC_DEFUN([CF_CHECK_CACHE],
 470 [
 471 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 472         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 473         system_name="$host_os"
 474 else
 475         system_name="`(uname -s -r) 2>/dev/null`"
 476         if test -z "$system_name" ; then
 477                 system_name="`(hostname) 2>/dev/null`"
 478         fi
 479 fi
 480 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 481 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 482
 483 test -z "$system_name" && system_name="$cf_cv_system_name"
 484 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 485
 486 if test ".$system_name" != ".$cf_cv_system_name" ; then
 487         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 488         AC_MSG_ERROR("Please remove config.cache and try again.")
 489 fi
 490 ])dnl
 491 dnl ---------------------------------------------------------------------------
 492 dnl CF_CHECK_CFLAGS version: 3 updated: 2014/07/22 05:32:57
 493 dnl ---------------
 494 dnl Conditionally add to $CFLAGS and $CPPFLAGS values which are derived from
 495 dnl a build-configuration such as imake.  These have the pitfall that they
 496 dnl often contain compiler-specific options which we cannot use, mixed with
 497 dnl preprocessor options that we usually can.
 498 AC_DEFUN([CF_CHECK_CFLAGS],
 499 [
 500 CF_VERBOSE(checking additions to CFLAGS)
 501 cf_check_cflags="$CFLAGS"
 502 cf_check_cppflags="$CPPFLAGS"
 503 CF_ADD_CFLAGS($1,yes)
 504 if test "x$cf_check_cflags" != "x$CFLAGS" ; then
 505 AC_TRY_LINK([#include <stdio.h>],[printf("Hello world");],,
 506         [CF_VERBOSE(test-compile failed.  Undoing change to \$CFLAGS)
 507          if test "x$cf_check_cppflags" != "x$CPPFLAGS" ; then
 508                  CF_VERBOSE(but keeping change to \$CPPFLAGS)
 509          fi
 510          CFLAGS="$cf_check_flags"])
 511 fi
 512 ])dnl
 513 dnl ---------------------------------------------------------------------------
 514 dnl CF_CHECK_CURSES_LIB version: 2 updated: 2018/01/03 04:47:33
 515 dnl -------------------
 516 dnl $1 = nominal library name, used also for header lookup
 517 dnl $2 = suffix to append to library name
 518 dnl $3 = function to check for using AC_CHECK_LIB
 519 dnl $4 = optional parameter list for $3
 520 AC_DEFUN([CF_CHECK_CURSES_LIB],
 521 [
 522 AC_REQUIRE([CF_PKG_CONFIG])
 523
 524 cf_have_curses_lib=no
 525
 526 : ${NCURSES_CONFIG_PKG:=none}
 527 if test "x${NCURSES_CONFIG_PKG}" = xnone; then
 528         :
 529 elif test "x${PKG_CONFIG:=none}" != xnone; then
 530         AC_MSG_CHECKING(pkg-config for $1$2)
 531         if "$PKG_CONFIG" --exists $1$2 ; then
 532                 AC_MSG_RESULT(yes)
 533
 534                 AC_MSG_CHECKING(if the $1$2 package files work)
 535
 536                 cf_save_CPPFLAGS="$CPPFLAGS"
 537                 cf_save_LIBS="$LIBS"
 538
 539                 CF_ADD_CFLAGS(`$PKG_CONFIG --cflags $1$2`)
 540                 CF_ADD_LIBS(`$PKG_CONFIG --libs $1$2`)
 541
 542                 AC_TRY_LINK([#include <$1.h>],
 543                         [(void) $3 ( ]ifelse([$4],,,[[$4]])[ );],
 544                         [AC_TRY_RUN([#include <$1.h>
 545                                 int main(void)
 546                                 { (void) $3 ( ]ifelse([$4],,,[[$4]])[ ); return 0; }],
 547                                 [cf_have_curses_lib=yes],
 548                                 [cf_have_curses_lib=no],
 549                                 [cf_have_curses_lib=maybe])],
 550                         [cf_have_curses_lib=no])
 551                 AC_MSG_RESULT($cf_have_curses_lib)
 552                 test "$cf_have_curses_lib" = maybe && cf_have_curses_lib=yes
 553                 if test "$cf_have_curses_lib" != "yes"
 554                 then
 555                         CPPFLAGS="$cf_save_CPPFLAGS"
 556                         LIBS="$cf_save_LIBS"
 557                 else
 558                         CF_UPPER(cf_upper,have_lib$1)
 559                         AC_DEFINE_UNQUOTED($cf_upper,1)
 560                 fi
 561         fi
 562 fi
 563 if test "$cf_have_curses_lib" = no; then
 564         AC_CHECK_LIB($1$2,$3,[
 565                 CF_UPPER(cf_upper,have_lib$1)
 566                 CF_ADD_LIBS(-l$1$2)
 567                 AC_DEFINE_UNQUOTED($cf_upper,1)])
 568 fi
 569 ])dnl
 570 dnl ---------------------------------------------------------------------------
 571 dnl CF_CLANG_COMPILER version: 4 updated: 2020/10/31 15:46:50
 572 dnl -----------------
 573 dnl Check if the given compiler is really clang.  clang's C driver defines
 574 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 575 dnl not ignore some gcc options.
 576 dnl
 577 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 578 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 579 dnl the wrappers for gcc and g++ warnings.
 580 dnl
 581 dnl $1 = GCC (default) or GXX
 582 dnl $2 = CLANG_COMPILER (default)
 583 dnl $3 = CFLAGS (default) or CXXFLAGS
 584 AC_DEFUN([CF_CLANG_COMPILER],[
 585 ifelse([$2],,CLANG_COMPILER,[$2])=no
 586
 587 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 588         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 589         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 590         AC_TRY_COMPILE([],[
 591 #ifdef __clang__
 592 #else
 593 make an error
 594 #endif
 595 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 596 ],[])
 597         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 598         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 599 fi
 600
 601 if test "x$ifelse([$2],,CLANG_COMPILER,[$2])" = "xyes" ; then
 602         for cf_clang_opt in \
 603                 -Qunused-arguments \
 604                 -Wno-error=implicit-function-declaration
 605         do
 606                 AC_MSG_CHECKING(if option $cf_clang_opt works)
 607                 AC_TRY_LINK([
 608                         #include <stdio.h>],[
 609                         printf("hello!\n");],[
 610                         cf_clang_optok=yes],[
 611                         cf_clang_optok=no])
 612                 AC_MSG_RESULT($cf_clang_optok)
 613                 if test $cf_clang_optok = yes; then
 614                         CF_VERBOSE(adding option $cf_clang_opt)
 615                         CF_APPEND_TEXT(CFLAGS,$cf_clang_opt)
 616                 fi
 617         done
 618 fi
 619 ])
 620 dnl ---------------------------------------------------------------------------
 621 dnl CF_CONST_X_STRING version: 4 updated: 2020/03/10 18:53:47
 622 dnl -----------------
 623 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
 624 dnl character-strings.
 625 dnl
 626 dnl It is ambiguous because the specification accommodated the pre-ANSI
 627 dnl compilers bundled by more than one vendor in lieu of providing a standard C
 628 dnl compiler other than by costly add-ons.  Because of this, the specification
 629 dnl did not take into account the use of const for telling the compiler that
 630 dnl string literals would be in readonly memory.
 631 dnl
 632 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
 633 dnl let the compiler decide how to represent Xt's strings which were #define'd.
 634 dnl That does not solve the problem of using the block of Xt's strings which
 635 dnl are compiled into the library (and is less efficient than one might want).
 636 dnl
 637 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
 638 dnl when compiling the library and compiling using the library, to tell the
 639 dnl compiler that String is const.
 640 AC_DEFUN([CF_CONST_X_STRING],
 641 [
 642 AC_REQUIRE([AC_PATH_XTRA])
 643
 644 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
 645
 646 AC_TRY_COMPILE(
 647 [
 648 #include <stdlib.h>
 649 #include <X11/Intrinsic.h>
 650 ],
 651 [String foo = malloc(1); (void)foo],[
 652
 653 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
 654         AC_TRY_COMPILE(
 655                 [
 656 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
 657 #undef  XTSTRINGDEFINES /* X11R5 and later */
 658 #include <stdlib.h>
 659 #include <X11/Intrinsic.h>
 660                 ],[String foo = malloc(1); *foo = 0],[
 661                         cf_cv_const_x_string=no
 662                 ],[
 663                         cf_cv_const_x_string=yes
 664                 ])
 665 ])
 666
 667 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
 668
 669 case $cf_cv_const_x_string in
 670 (no)
 671         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
 672         ;;
 673 (*)
 674         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
 675         ;;
 676 esac
 677
 678 ])
 679 ])dnl
 680 dnl ---------------------------------------------------------------------------
 681 dnl CF_CURSES_ACS_MAP version: 7 updated: 2012/10/06 16:39:58
 682 dnl -----------------
 683 dnl Check for likely values of acs_map[]:
 684 AC_DEFUN([CF_CURSES_ACS_MAP],
 685 [
 686 AC_REQUIRE([CF_NCURSES_WRAP_PREFIX])dnl
 687 AC_CACHE_CHECK(for alternate character set array, cf_cv_curses_acs_map,[
 688 cf_cv_curses_acs_map=unknown
 689 for name in acs_map _acs_map __acs_map ${NCURSES_WRAP_PREFIX}acs_map
 690 do
 691 AC_TRY_LINK([
 692 #include <${cf_cv_ncurses_header:-curses.h}>
 693 ],[
 694 $name['k'] = ACS_PLUS
 695 ],[cf_cv_curses_acs_map=$name; break])
 696 done
 697 ])
 698
 699 test "$cf_cv_curses_acs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_ACS_ARRAY,$cf_cv_curses_acs_map,[Define as needed to override ncurses prefix _nc_])
 700 ])
 701 dnl ---------------------------------------------------------------------------
 702 dnl CF_CURSES_CHECK_DATA version: 9 updated: 2020/02/08 21:00:26
 703 dnl --------------------
 704 dnl Check if curses.h defines the given data/variable.
 705 dnl Use this after CF_NCURSES_CONFIG or CF_CURSES_CONFIG.
 706 dnl
 707 dnl $1 = data item(s) to check for
 708 dnl $2 = action on success, e.g., "break" to quit checking a series of choices
 709 AC_DEFUN([CF_CURSES_CHECK_DATA],
 710 [
 711 for cf_data in $1
 712 do
 713 AC_MSG_CHECKING(for data $cf_data declaration in ${cf_cv_ncurses_header:-curses.h})
 714
 715 AC_TRY_COMPILE(CF__CURSES_HEAD,
 716 CF__CURSES_DATA(foo,$cf_data)
 717 ,[cf_result=yes
 718 ],[cf_result=no])
 719 AC_MSG_RESULT($cf_result)
 720
 721 if test $cf_result = yes ; then
 722         CF_UPPER(cf_result,have_curses_data_$cf_data)
 723         AC_DEFINE_UNQUOTED($cf_result)
 724         ifelse($2,,,[$2])
 725 else
 726         AC_MSG_CHECKING(for data $cf_data in library)
 727         # BSD linkers insist on making weak linkage, but resolve at runtime.
 728         AC_TRY_RUN(CF__CURSES_HEAD
 729 [
 730 extern char $cf_data;
 731 int main(void)
 732 {
 733         ]CF__CURSES_DATA(foo,$cf_data)[
 734         ${cf_cv_main_return:-return}(foo == 0);
 735 }],[cf_result=yes
 736 ],[cf_result=no],[
 737         # cross-compiling
 738         AC_TRY_LINK(CF__CURSES_HEAD
 739 [extern char $cf_data;],[
 740         do {
 741                 ]CF__CURSES_DATA(foo,$cf_data)[
 742                 ${cf_cv_main_return:-return}(foo == 0);
 743         } while (0)
 744 ],[cf_result=yes],[cf_result=no])
 745 ])
 746         AC_MSG_RESULT($cf_result)
 747         if test $cf_result = yes ; then
 748                 CF_UPPER(cf_result,decl_curses_data_$cf_data)
 749                 AC_DEFINE_UNQUOTED($cf_result)
 750                 # do not exit loop here, since we prefer system's declarations
 751         fi
 752 fi
 753 done
 754 ])dnl
 755 dnl ---------------------------------------------------------------------------
 756 dnl CF_CURSES_CHECK_TYPE version: 4 updated: 2012/10/06 16:39:58
 757 dnl --------------------
 758 dnl Check if curses.h defines the given type
 759 AC_DEFUN([CF_CURSES_CHECK_TYPE],
 760 [
 761 AC_MSG_CHECKING(for type $1 in ${cf_cv_ncurses_header:-curses.h})
 762 AC_TRY_COMPILE([
 763 #ifndef _XOPEN_SOURCE_EXTENDED
 764 #define _XOPEN_SOURCE_EXTENDED
 765 #endif
 766 #include <${cf_cv_ncurses_header:-curses.h}>],[
 767 $1 foo
 768 ],cf_result=yes,cf_result=no)
 769 AC_MSG_RESULT($cf_result)
 770 if test $cf_result = yes ; then
 771         CF_UPPER(cf_result,have_type_$1)
 772         AC_DEFINE_UNQUOTED($cf_result,1,[Define to 1 if we have type $1])
 773 else
 774         AC_DEFINE_UNQUOTED($1,$2,[Define to appropriate type if $1 is not declared])
 775 fi
 776 ])dnl
 777 dnl ---------------------------------------------------------------------------
 778 dnl CF_CURSES_CONFIG version: 2 updated: 2006/10/29 11:06:27
 779 dnl ----------------
 780 dnl Tie together the configure-script macros for curses.  It may be ncurses,
 781 dnl but unless asked, we do not make a special search for ncurses.  However,
 782 dnl still check for the ncurses version number, for use in other macros.
 783 AC_DEFUN([CF_CURSES_CONFIG],
 784 [
 785 CF_CURSES_CPPFLAGS
 786 CF_NCURSES_VERSION
 787 CF_CURSES_LIBS
 788 ])dnl
 789 dnl ---------------------------------------------------------------------------
 790 dnl CF_CURSES_CPPFLAGS version: 13 updated: 2018/06/20 20:23:13
 791 dnl ------------------
 792 dnl Look for the curses headers.
 793 AC_DEFUN([CF_CURSES_CPPFLAGS],[
 794
 795 AC_CACHE_CHECK(for extra include directories,cf_cv_curses_incdir,[
 796 cf_cv_curses_incdir=no
 797 case $host_os in
 798 (hpux10.*)
 799         if test "x$cf_cv_screen" = "xcurses_colr"
 800         then
 801                 test -d /usr/include/curses_colr && \
 802                 cf_cv_curses_incdir="-I/usr/include/curses_colr"
 803         fi
 804         ;;
 805 (sunos3*|sunos4*)
 806         if test "x$cf_cv_screen" = "xcurses_5lib"
 807         then
 808                 test -d /usr/5lib && \
 809                 test -d /usr/5include && \
 810                 cf_cv_curses_incdir="-I/usr/5include"
 811         fi
 812         ;;
 813 esac
 814 ])
 815 if test "$cf_cv_curses_incdir" != no
 816 then
 817         CF_APPEND_TEXT(CPPFLAGS,$cf_cv_curses_incdir)
 818 fi
 819
 820 CF_CURSES_HEADER
 821 CF_TERM_HEADER
 822 ])dnl
 823 dnl ---------------------------------------------------------------------------
 824 dnl CF_CURSES_FUNCS version: 19 updated: 2018/01/03 04:47:33
 825 dnl ---------------
 826 dnl Curses-functions are a little complicated, since a lot of them are macros.
 827 AC_DEFUN([CF_CURSES_FUNCS],
 828 [
 829 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 830 AC_REQUIRE([CF_XOPEN_CURSES])
 831 AC_REQUIRE([CF_CURSES_TERM_H])
 832 AC_REQUIRE([CF_CURSES_UNCTRL_H])
 833 for cf_func in $1
 834 do
 835         CF_UPPER(cf_tr_func,$cf_func)
 836         AC_MSG_CHECKING(for ${cf_func})
 837         CF_MSG_LOG(${cf_func})
 838         AC_CACHE_VAL(cf_cv_func_$cf_func,[
 839                 eval cf_result='$ac_cv_func_'$cf_func
 840                 if test ".$cf_result" != ".no"; then
 841                         AC_TRY_LINK(CF__CURSES_HEAD,
 842                         [
 843 #ifndef ${cf_func}
 844 long foo = (long)(&${cf_func});
 845 fprintf(stderr, "testing linkage of $cf_func:%p\n", (void *)foo);
 846 if (foo + 1234L > 5678L)
 847         ${cf_cv_main_return:-return}(foo != 0);
 848 #endif
 849                         ],
 850                         [cf_result=yes],
 851                         [cf_result=no])
 852                 fi
 853                 eval 'cf_cv_func_'$cf_func'=$cf_result'
 854         ])
 855         # use the computed/retrieved cache-value:
 856         eval 'cf_result=$cf_cv_func_'$cf_func
 857         AC_MSG_RESULT($cf_result)
 858         if test $cf_result != no; then
 859                 AC_DEFINE_UNQUOTED(HAVE_${cf_tr_func})
 860         fi
 861 done
 862 ])dnl
 863 dnl ---------------------------------------------------------------------------
 864 dnl CF_CURSES_HEADER version: 5 updated: 2015/04/23 20:35:30
 865 dnl ----------------
 866 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
 867 dnl variations of ncurses' installs.
 868 dnl
 869 dnl $1 = ncurses when looking for ncurses, or is empty
 870 AC_DEFUN([CF_CURSES_HEADER],[
 871 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
 872 cf_cv_ncurses_header=none
 873 for cf_header in \
 874         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
 875         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
 876 do
 877 AC_TRY_COMPILE([#include <${cf_header}>],
 878         [initscr(); tgoto("?", 0,0)],
 879         [cf_cv_ncurses_header=$cf_header; break],[])
 880 done
 881 ])
 882
 883 if test "$cf_cv_ncurses_header" = none ; then
 884         AC_MSG_ERROR(No curses header-files found)
 885 fi
 886
 887 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
 888 AC_CHECK_HEADERS($cf_cv_ncurses_header)
 889 ])dnl
 890 dnl ---------------------------------------------------------------------------
 891 dnl CF_CURSES_LIBS version: 42 updated: 2018/06/20 20:23:13
 892 dnl --------------
 893 dnl Look for the curses libraries.  Older curses implementations may require
 894 dnl termcap/termlib to be linked as well.  Call CF_CURSES_CPPFLAGS first.
 895 AC_DEFUN([CF_CURSES_LIBS],[
 896
 897 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 898 AC_MSG_CHECKING(if we have identified curses libraries)
 899 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 900         [initscr(); tgoto("?", 0,0)],
 901         cf_result=yes,
 902         cf_result=no)
 903 AC_MSG_RESULT($cf_result)
 904
 905 if test "$cf_result" = no ; then
 906 case $host_os in
 907 (freebsd*)
 908         AC_CHECK_LIB(mytinfo,tgoto,[CF_ADD_LIBS(-lmytinfo)])
 909         ;;
 910 (hpux10.*)
 911         # Looking at HPUX 10.20, the Hcurses library is the oldest (1997), cur_colr
 912         # next (1998), and xcurses "newer" (2000).  There is no header file for
 913         # Hcurses; the subdirectory curses_colr has the headers (curses.h and
 914         # term.h) for cur_colr
 915         if test "x$cf_cv_screen" = "xcurses_colr"
 916         then
 917                 AC_CHECK_LIB(cur_colr,initscr,[
 918                         CF_ADD_LIBS(-lcur_colr)
 919                         ac_cv_func_initscr=yes
 920                         ],[
 921                 AC_CHECK_LIB(Hcurses,initscr,[
 922                         # HP's header uses __HP_CURSES, but user claims _HP_CURSES.
 923                         CF_ADD_LIBS(-lHcurses)
 924                         CF_APPEND_TEXT(CPPFLAGS,-D__HP_CURSES -D_HP_CURSES)
 925                         ac_cv_func_initscr=yes
 926                         ])])
 927         fi
 928         ;;
 929 (linux*)
 930         case `arch 2>/dev/null` in
 931         (x86_64)
 932                 if test -d /lib64
 933                 then
 934                         CF_ADD_LIBDIR(/lib64)
 935                 else
 936                         CF_ADD_LIBDIR(/lib)
 937                 fi
 938                 ;;
 939         (*)
 940                 CF_ADD_LIBDIR(/lib)
 941                 ;;
 942         esac
 943         ;;
 944 (sunos3*|sunos4*)
 945         if test "x$cf_cv_screen" = "xcurses_5lib"
 946         then
 947                 if test -d /usr/5lib ; then
 948                         CF_ADD_LIBDIR(/usr/5lib)
 949                         CF_ADD_LIBS(-lcurses -ltermcap)
 950                 fi
 951         fi
 952         ac_cv_func_initscr=yes
 953         ;;
 954 esac
 955
 956 if test ".$ac_cv_func_initscr" != .yes ; then
 957         cf_save_LIBS="$LIBS"
 958
 959         if test ".${cf_cv_ncurses_version:-no}" != .no
 960         then
 961                 cf_check_list="ncurses curses cursesX"
 962         else
 963                 cf_check_list="cursesX curses ncurses"
 964         fi
 965
 966         # Check for library containing tgoto.  Do this before curses library
 967         # because it may be needed to link the test-case for initscr.
 968         if test "x$cf_term_lib" = x
 969         then
 970                 AC_CHECK_FUNC(tgoto,[cf_term_lib=predefined],[
 971                         for cf_term_lib in $cf_check_list otermcap termcap tinfo termlib unknown
 972                         do
 973                                 AC_CHECK_LIB($cf_term_lib,tgoto,[
 974                                         : ${cf_nculib_root:=$cf_term_lib}
 975                                         break
 976                                 ])
 977                         done
 978                 ])
 979         fi
 980
 981         # Check for library containing initscr
 982         test "$cf_term_lib" != predefined && test "$cf_term_lib" != unknown && LIBS="-l$cf_term_lib $cf_save_LIBS"
 983         if test "x$cf_curs_lib" = x
 984         then
 985                 for cf_curs_lib in $cf_check_list xcurses jcurses pdcurses unknown
 986                 do
 987                         LIBS="-l$cf_curs_lib $cf_save_LIBS"
 988                         if test "$cf_term_lib" = unknown || test "$cf_term_lib" = "$cf_curs_lib" ; then
 989                                 AC_MSG_CHECKING(if we can link with $cf_curs_lib library)
 990                                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 991                                         [initscr()],
 992                                         [cf_result=yes],
 993                                         [cf_result=no])
 994                                 AC_MSG_RESULT($cf_result)
 995                                 test $cf_result = yes && break
 996                         elif test "$cf_curs_lib" = "$cf_term_lib" ; then
 997                                 cf_result=no
 998                         elif test "$cf_term_lib" != predefined ; then
 999                                 AC_MSG_CHECKING(if we need both $cf_curs_lib and $cf_term_lib libraries)
1000                                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
1001                                         [initscr(); tgoto((char *)0, 0, 0);],
1002                                         [cf_result=no],
1003                                         [
1004                                         LIBS="-l$cf_curs_lib -l$cf_term_lib $cf_save_LIBS"
1005                                         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
1006                                                 [initscr()],
1007                                                 [cf_result=yes],
1008                                                 [cf_result=error])
1009                                         ])
1010                                 AC_MSG_RESULT($cf_result)
1011                                 test $cf_result != error && break
1012                         fi
1013                 done
1014         fi
1015         test $cf_curs_lib = unknown && AC_MSG_ERROR(no curses library found)
1016 fi
1017 fi
1018
1019 ])dnl
1020 dnl ---------------------------------------------------------------------------
1021 dnl CF_CURSES_TERM_H version: 12 updated: 2020/03/19 20:23:48
1022 dnl ----------------
1023 dnl SVr4 curses should have term.h as well (where it puts the definitions of
1024 dnl the low-level interface).  This may not be true in old/broken implementations,
1025 dnl as well as in misconfigured systems (e.g., gcc configured for Solaris 2.4
1026 dnl running with Solaris 2.5.1).
1027 AC_DEFUN([CF_CURSES_TERM_H],
1028 [
1029 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
1030
1031 AC_CACHE_CHECK(for term.h, cf_cv_term_header,[
1032
1033 # If we found <ncurses/curses.h>, look for <ncurses/term.h>, but always look
1034 # for <term.h> if we do not find the variant.
1035
1036 cf_header_list="term.h ncurses/term.h ncursesw/term.h"
1037
1038 case ${cf_cv_ncurses_header:-curses.h} in
1039 (*/*)
1040         cf_header_item=`echo ${cf_cv_ncurses_header:-curses.h} | sed -e 's%\..*%%' -e 's%/.*%/%'`term.h
1041         cf_header_list="$cf_header_item $cf_header_list"
1042         ;;
1043 esac
1044
1045 for cf_header in $cf_header_list
1046 do
1047         AC_TRY_COMPILE([
1048 #include <${cf_cv_ncurses_header:-curses.h}>
1049 #include <${cf_header}>],
1050         [WINDOW *x; (void)x],
1051         [cf_cv_term_header=$cf_header
1052          break],
1053         [cf_cv_term_header=no])
1054 done
1055
1056 case $cf_cv_term_header in
1057 (no)
1058         # If curses is ncurses, some packagers still mess it up by trying to make
1059         # us use GNU termcap.  This handles the most common case.
1060         for cf_header in ncurses/term.h ncursesw/term.h
1061         do
1062                 AC_TRY_COMPILE([
1063 #include <${cf_cv_ncurses_header:-curses.h}>
1064 #ifdef NCURSES_VERSION
1065 #include <${cf_header}>
1066 #else
1067 make an error
1068 #endif],
1069                         [WINDOW *x; (void)x],
1070                         [cf_cv_term_header=$cf_header
1071                          break],
1072                         [cf_cv_term_header=no])
1073         done
1074         ;;
1075 esac
1076 ])
1077
1078 case $cf_cv_term_header in
1079 (term.h)
1080         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
1081         ;;
1082 (ncurses/term.h)
1083         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
1084         ;;
1085 (ncursesw/term.h)
1086         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
1087         ;;
1088 esac
1089 ])dnl
1090 dnl ---------------------------------------------------------------------------
1091 dnl CF_CURSES_UNCTRL_H version: 5 updated: 2020/03/19 20:23:48
1092 dnl ------------------
1093 dnl Any X/Open curses implementation must have unctrl.h, but ncurses packages
1094 dnl may put it in a subdirectory (along with ncurses' other headers, of
1095 dnl course).  Packages which put the headers in inconsistent locations are
1096 dnl broken).
1097 AC_DEFUN([CF_CURSES_UNCTRL_H],
1098 [
1099 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
1100
1101 AC_CACHE_CHECK(for unctrl.h, cf_cv_unctrl_header,[
1102
1103 # If we found <ncurses/curses.h>, look for <ncurses/unctrl.h>, but always look
1104 # for <unctrl.h> if we do not find the variant.
1105
1106 cf_header_list="unctrl.h ncurses/unctrl.h ncursesw/unctrl.h"
1107
1108 case ${cf_cv_ncurses_header:-curses.h} in
1109 (*/*)
1110         cf_header_item=`echo ${cf_cv_ncurses_header:-curses.h} | sed -e 's%\..*%%' -e 's%/.*%/%'`unctrl.h
1111         cf_header_list="$cf_header_item $cf_header_list"
1112         ;;
1113 esac
1114
1115 for cf_header in $cf_header_list
1116 do
1117         AC_TRY_COMPILE([
1118 #include <${cf_cv_ncurses_header:-curses.h}>
1119 #include <${cf_header}>],
1120         [WINDOW *x; (void)x],
1121         [cf_cv_unctrl_header=$cf_header
1122          break],
1123         [cf_cv_unctrl_header=no])
1124 done
1125 ])
1126
1127 case $cf_cv_unctrl_header in
1128 (no)
1129         AC_MSG_WARN(unctrl.h header not found)
1130         ;;
1131 esac
1132
1133 case $cf_cv_unctrl_header in
1134 (unctrl.h)
1135         AC_DEFINE(HAVE_UNCTRL_H,1,[Define to 1 if we have unctrl.h])
1136         ;;
1137 (ncurses/unctrl.h)
1138         AC_DEFINE(HAVE_NCURSES_UNCTRL_H,1,[Define to 1 if we have ncurses/unctrl.h])
1139         ;;
1140 (ncursesw/unctrl.h)
1141         AC_DEFINE(HAVE_NCURSESW_UNCTRL_H,1,[Define to 1 if we have ncursesw/unctrl.h])
1142         ;;
1143 esac
1144 ])dnl
1145 dnl ---------------------------------------------------------------------------
1146 dnl CF_CURSES_WACS_MAP version: 7 updated: 2020/03/19 20:23:48
1147 dnl ------------------
1148 dnl Check for likely values of wacs_map[].
1149 AC_DEFUN([CF_CURSES_WACS_MAP],
1150 [
1151 AC_CACHE_CHECK(for wide alternate character set array, cf_cv_curses_wacs_map,[
1152         cf_cv_curses_wacs_map=unknown
1153         for name in wacs_map _wacs_map __wacs_map _nc_wacs _wacs_char
1154         do
1155         AC_TRY_LINK([
1156 #ifndef _XOPEN_SOURCE_EXTENDED
1157 #define _XOPEN_SOURCE_EXTENDED
1158 #endif
1159 #include <${cf_cv_ncurses_header:-curses.h}>],
1160         [void *foo = &($name['k']); (void)foo],
1161         [cf_cv_curses_wacs_map=$name
1162          break])
1163         done])
1164
1165 test "$cf_cv_curses_wacs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_WACS_ARRAY,$cf_cv_curses_wacs_map,[Define to name of (n)curses wide-character array])
1166 ])dnl
1167 dnl ---------------------------------------------------------------------------
1168 dnl CF_CURSES_WACS_SYMBOLS version: 3 updated: 2020/03/19 20:23:48
1169 dnl ----------------------
1170 dnl Do a check to see if the WACS_xxx constants are defined compatibly with
1171 dnl X/Open Curses.  In particular, NetBSD's implementation of the WACS_xxx
1172 dnl constants is broken since those constants do not point to cchar_t's.
1173 AC_DEFUN([CF_CURSES_WACS_SYMBOLS],
1174 [
1175 AC_REQUIRE([CF_CURSES_WACS_MAP])
1176
1177 AC_CACHE_CHECK(for wide alternate character constants, cf_cv_curses_wacs_symbols,[
1178 cf_cv_curses_wacs_symbols=no
1179 if test "$cf_cv_curses_wacs_map" != unknown
1180 then
1181         AC_TRY_LINK([
1182 #ifndef _XOPEN_SOURCE_EXTENDED
1183 #define _XOPEN_SOURCE_EXTENDED
1184 #endif
1185 #include <${cf_cv_ncurses_header:-curses.h}>],
1186         [cchar_t *foo = WACS_PLUS;
1187          $cf_cv_curses_wacs_map['k'] = *WACS_PLUS; (void)foo],
1188         [cf_cv_curses_wacs_symbols=yes])
1189 else
1190         AC_TRY_LINK([
1191 #ifndef _XOPEN_SOURCE_EXTENDED
1192 #define _XOPEN_SOURCE_EXTENDED
1193 #endif
1194 #include <${cf_cv_ncurses_header:-curses.h}>],
1195         [cchar_t *foo = WACS_PLUS; (void)foo],
1196         [cf_cv_curses_wacs_symbols=yes])
1197 fi
1198 ])
1199
1200 test "$cf_cv_curses_wacs_symbols" != no && AC_DEFINE(CURSES_WACS_SYMBOLS,1,[Define to 1 if (n)curses supports wide-character WACS_ symbols])
1201 ])dnl
1202 dnl ---------------------------------------------------------------------------
1203 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1204 dnl ----------
1205 dnl "dirname" is not portable, so we fake it with a shell script.
1206 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1207 dnl ---------------------------------------------------------------------------
1208 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1209 dnl ---------------
1210 dnl You can always use "make -n" to see the actual options, but it's hard to
1211 dnl pick out/analyze warning messages when the compile-line is long.
1212 dnl
1213 dnl Sets:
1214 dnl     ECHO_LT - symbol to control if libtool is verbose
1215 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1216 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1217 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1218 dnl     ECHO_CC - symbol to put before any "cc" line
1219 dnl
1220 AC_DEFUN([CF_DISABLE_ECHO],[
1221 AC_MSG_CHECKING(if you want to see long compiling messages)
1222 CF_ARG_DISABLE(echo,
1223         [  --disable-echo          do not display "compiling" commands],
1224         [
1225         ECHO_LT='--silent'
1226         ECHO_LD='@echo linking [$]@;'
1227         RULE_CC='@echo compiling [$]<'
1228         SHOW_CC='@echo compiling [$]@'
1229         ECHO_CC='@'
1230 ],[
1231         ECHO_LT=''
1232         ECHO_LD=''
1233         RULE_CC=''
1234         SHOW_CC=''
1235         ECHO_CC=''
1236 ])
1237 AC_MSG_RESULT($enableval)
1238 AC_SUBST(ECHO_LT)
1239 AC_SUBST(ECHO_LD)
1240 AC_SUBST(RULE_CC)
1241 AC_SUBST(SHOW_CC)
1242 AC_SUBST(ECHO_CC)
1243 ])dnl
1244 dnl ---------------------------------------------------------------------------
1245 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1246 dnl ----------------
1247 dnl Combine no-leak checks with the libraries or tools that are used for the
1248 dnl checks.
1249 AC_DEFUN([CF_DISABLE_LEAKS],[
1250
1251 AC_REQUIRE([CF_WITH_DMALLOC])
1252 AC_REQUIRE([CF_WITH_DBMALLOC])
1253 AC_REQUIRE([CF_WITH_VALGRIND])
1254
1255 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1256 AC_ARG_ENABLE(leaks,
1257         [  --disable-leaks         test: free permanent memory, analyze leaks],
1258         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1259         : ${with_no_leaks:=no})
1260 AC_MSG_RESULT($with_no_leaks)
1261
1262 if test "$with_no_leaks" = yes ; then
1263         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1264         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1265 fi
1266 ])dnl
1267 dnl ---------------------------------------------------------------------------
1268 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1269 dnl ---------------------
1270 dnl The rpath-hack makes it simpler to build programs, particularly with the
1271 dnl *BSD ports which may have essential libraries in unusual places.  But it
1272 dnl can interfere with building an executable for the base system.  Use this
1273 dnl option in that case.
1274 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1275 [
1276 AC_MSG_CHECKING(if rpath-hack should be disabled)
1277 CF_ARG_DISABLE(rpath-hack,
1278         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1279         [cf_disable_rpath_hack=yes],
1280         [cf_disable_rpath_hack=no])
1281 AC_MSG_RESULT($cf_disable_rpath_hack)
1282 if test "$cf_disable_rpath_hack" = no ; then
1283         CF_RPATH_HACK
1284 fi
1285 ])
1286 dnl ---------------------------------------------------------------------------
1287 dnl CF_ENABLE_STRING_HACKS version: 5 updated: 2016/10/08 17:34:11
1288 dnl ----------------------
1289 dnl On a few platforms, the compiler and/or loader nags with untruthful
1290 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1291 dnl and implying that most uses of the recommended alternatives are correct.
1292 dnl
1293 dnl Factually speaking, no one has actually counted the number of uses of these
1294 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1295 dnl instances are meaningless compared to the hundreds of millions of lines of
1296 dnl existing C code.
1297 dnl
1298 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1299 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1300 dnl standard - but evolved through phases, and older implementations are likely
1301 dnl to yield surprising results, as documented in manpages on various systems.
1302 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1303 [
1304 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1305 AC_ARG_ENABLE(string-hacks,
1306         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1307         [with_string_hacks=$enableval],
1308         [with_string_hacks=no])
1309 AC_MSG_RESULT($with_string_hacks)
1310
1311 if test "x$with_string_hacks" = "xyes"; then
1312         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1313         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1314         AC_CHECK_FUNC(strlcat,[
1315                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1316                 ],[
1317                 AC_CHECK_LIB(bsd,strlcat,[
1318                         CF_ADD_LIB(bsd)
1319                         AC_CHECK_HEADERS(bsd/string.h)
1320                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1321                         ])
1322                 ])
1323         AC_CHECK_FUNCS( strlcpy snprintf )
1324 fi
1325 ])dnl
1326 dnl ---------------------------------------------------------------------------
1327 dnl CF_ENABLE_WARNINGS version: 7 updated: 2020/08/29 09:05:21
1328 dnl ------------------
1329 dnl Configure-option to enable gcc warnings
1330 dnl
1331 dnl $1 = extra options to add, if supported
1332 dnl $2 = option for checking attributes.  By default, this is done when
1333 dnl      warnings are enabled.  For other values:
1334 dnl      yes: always do this, e.g., to use in generated library-headers
1335 dnl      no: never do this
1336 AC_DEFUN([CF_ENABLE_WARNINGS],[
1337 if ( test "$GCC" = yes || test "$GXX" = yes )
1338 then
1339 CF_FIX_WARNINGS(CFLAGS)
1340 CF_FIX_WARNINGS(CPPFLAGS)
1341 CF_FIX_WARNINGS(LDFLAGS)
1342 AC_MSG_CHECKING(if you want to turn on gcc warnings)
1343 CF_ARG_ENABLE(warnings,
1344         [  --enable-warnings       test: turn on gcc compiler warnings],
1345         [with_warnings=yes],
1346         [with_warnings=no])
1347 AC_MSG_RESULT($with_warnings)
1348 if test "$with_warnings" = "yes"
1349 then
1350         ifelse($2,,[CF_GCC_ATTRIBUTES])
1351         CF_GCC_WARNINGS($1)
1352 fi
1353 ifelse($2,yes,[CF_GCC_ATTRIBUTES])
1354 fi
1355 ])dnl
1356 dnl ---------------------------------------------------------------------------
1357 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
1358 dnl ---------------
1359 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
1360 dnl prefer a standard location, and use -L options only if we do not find the
1361 dnl library in the standard library location(s).
1362 dnl     $1 = library name
1363 dnl     $2 = library class, usually the same as library name
1364 dnl     $3 = includes
1365 dnl     $4 = code fragment to compile/link
1366 dnl     $5 = corresponding function-name
1367 dnl     $6 = flag, nonnull if failure should not cause an error-exit
1368 dnl
1369 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
1370 dnl to use a -L option.
1371 AC_DEFUN([CF_FIND_LIBRARY],
1372 [
1373         eval 'cf_cv_have_lib_'$1'=no'
1374         cf_libdir=""
1375         AC_CHECK_FUNC($5,
1376                 eval 'cf_cv_have_lib_'$1'=yes',[
1377                 cf_save_LIBS="$LIBS"
1378                 AC_MSG_CHECKING(for $5 in -l$1)
1379                 LIBS="-l$1 $LIBS"
1380                 AC_TRY_LINK([$3],[$4],
1381                         [AC_MSG_RESULT(yes)
1382                          eval 'cf_cv_have_lib_'$1'=yes'
1383                         ],
1384                         [AC_MSG_RESULT(no)
1385                         CF_LIBRARY_PATH(cf_search,$2)
1386                         for cf_libdir in $cf_search
1387                         do
1388                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
1389                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
1390                                 AC_TRY_LINK([$3],[$4],
1391                                         [AC_MSG_RESULT(yes)
1392                                          eval 'cf_cv_have_lib_'$1'=yes'
1393                                          break],
1394                                         [AC_MSG_RESULT(no)
1395                                          LIBS="$cf_save_LIBS"])
1396                         done
1397                         ])
1398                 ])
1399 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
1400 ifelse($6,,[
1401 if test $cf_found_library = no ; then
1402         AC_MSG_ERROR(Cannot link $1 library)
1403 fi
1404 ])
1405 ])dnl
1406 dnl ---------------------------------------------------------------------------
1407 dnl CF_FIND_LINKAGE version: 21 updated: 2018/06/20 20:23:13
1408 dnl ---------------
1409 dnl Find a library (specifically the linkage used in the code fragment),
1410 dnl searching for it if it is not already in the library path.
1411 dnl See also CF_ADD_SEARCHPATH.
1412 dnl
1413 dnl Parameters (4-on are optional):
1414 dnl     $1 = headers for library entrypoint
1415 dnl     $2 = code fragment for library entrypoint
1416 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1417 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1418 dnl     $5 = action to perform if not successful
1419 dnl     $6 = module name, if not the same as the library name
1420 dnl     $7 = extra libraries
1421 dnl
1422 dnl Sets these variables:
1423 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1424 dnl     $cf_cv_header_path_$3 - include-directory if needed
1425 dnl     $cf_cv_library_path_$3 - library-directory if needed
1426 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1427 AC_DEFUN([CF_FIND_LINKAGE],[
1428
1429 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1430 # will be set on completion of the AC_TRY_LINK below.
1431 cf_cv_header_path_$3=
1432 cf_cv_library_path_$3=
1433
1434 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1435
1436 cf_save_LIBS="$LIBS"
1437
1438 AC_TRY_LINK([$1],[$2],[
1439         cf_cv_find_linkage_$3=yes
1440         cf_cv_header_path_$3=/usr/include
1441         cf_cv_library_path_$3=/usr/lib
1442 ],[
1443
1444 LIBS="-l$3 $7 $cf_save_LIBS"
1445
1446 AC_TRY_LINK([$1],[$2],[
1447         cf_cv_find_linkage_$3=yes
1448         cf_cv_header_path_$3=/usr/include
1449         cf_cv_library_path_$3=/usr/lib
1450         cf_cv_library_file_$3="-l$3"
1451 ],[
1452         cf_cv_find_linkage_$3=no
1453         LIBS="$cf_save_LIBS"
1454
1455         CF_VERBOSE(find linkage for $3 library)
1456         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1457
1458         cf_save_CPPFLAGS="$CPPFLAGS"
1459         cf_test_CPPFLAGS="$CPPFLAGS"
1460
1461         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1462         for cf_cv_header_path_$3 in $cf_search
1463         do
1464                 if test -d $cf_cv_header_path_$3 ; then
1465                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1466                         CPPFLAGS="$cf_save_CPPFLAGS"
1467                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
1468                         AC_TRY_COMPILE([$1],[$2],[
1469                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1470                                 cf_cv_find_linkage_$3=maybe
1471                                 cf_test_CPPFLAGS="$CPPFLAGS"
1472                                 break],[
1473                                 CPPFLAGS="$cf_save_CPPFLAGS"
1474                                 ])
1475                 fi
1476         done
1477
1478         if test "$cf_cv_find_linkage_$3" = maybe ; then
1479
1480                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1481
1482                 cf_save_LIBS="$LIBS"
1483                 cf_save_LDFLAGS="$LDFLAGS"
1484
1485                 ifelse([$6],,,[
1486                 CPPFLAGS="$cf_test_CPPFLAGS"
1487                 LIBS="-l$3 $7 $cf_save_LIBS"
1488                 AC_TRY_LINK([$1],[$2],[
1489                         CF_VERBOSE(... found $3 library in system)
1490                         cf_cv_find_linkage_$3=yes])
1491                         CPPFLAGS="$cf_save_CPPFLAGS"
1492                         LIBS="$cf_save_LIBS"
1493                         ])
1494
1495                 if test "$cf_cv_find_linkage_$3" != yes ; then
1496                         CF_LIBRARY_PATH(cf_search,$3)
1497                         for cf_cv_library_path_$3 in $cf_search
1498                         do
1499                                 if test -d $cf_cv_library_path_$3 ; then
1500                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1501                                         CPPFLAGS="$cf_test_CPPFLAGS"
1502                                         LIBS="-l$3 $7 $cf_save_LIBS"
1503                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1504                                         AC_TRY_LINK([$1],[$2],[
1505                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1506                                         cf_cv_find_linkage_$3=yes
1507                                         cf_cv_library_file_$3="-l$3"
1508                                         break],[
1509                                         CPPFLAGS="$cf_save_CPPFLAGS"
1510                                         LIBS="$cf_save_LIBS"
1511                                         LDFLAGS="$cf_save_LDFLAGS"
1512                                         ])
1513                                 fi
1514                         done
1515                         CPPFLAGS="$cf_save_CPPFLAGS"
1516                         LDFLAGS="$cf_save_LDFLAGS"
1517                 fi
1518
1519         else
1520                 cf_cv_find_linkage_$3=no
1521         fi
1522         ],$7)
1523 ])
1524
1525 LIBS="$cf_save_LIBS"
1526
1527 if test "$cf_cv_find_linkage_$3" = yes ; then
1528 ifelse([$4],,[
1529         CF_ADD_INCDIR($cf_cv_header_path_$3)
1530         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1531         CF_ADD_LIB($3)
1532 ],[$4])
1533 else
1534 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1535 fi
1536 ])dnl
1537 dnl ---------------------------------------------------------------------------
1538 dnl CF_FIX_WARNINGS version: 2 updated: 2020/08/28 15:08:28
1539 dnl ---------------
1540 dnl Warning flags do not belong in CFLAGS, CPPFLAGS, etc.  Any of gcc's
1541 dnl "-Werror" flags can interfere with configure-checks.  Those go into
1542 dnl EXTRA_CFLAGS.
1543 dnl
1544 dnl $1 = variable name to repair
1545 define([CF_FIX_WARNINGS],[
1546 if ( test "$GCC" = yes || test "$GXX" = yes )
1547 then
1548         case [$]$1 in
1549         (*-Werror=*)
1550                 CF_VERBOSE(repairing $1: [$]$1)
1551                 cf_temp_flags=
1552                 for cf_temp_scan in [$]$1
1553                 do
1554                         case "x$cf_temp_scan" in
1555                         (x-Werror=*)
1556                                 CF_APPEND_TEXT(EXTRA_CFLAGS,"$cf_temp_scan")
1557                                 ;;
1558                         (*)
1559                                 CF_APPEND_TEXT(cf_temp_flags,"$cf_temp_scan")
1560                                 ;;
1561                         esac
1562                 done
1563                 $1="$cf_temp_flags"
1564                 CF_VERBOSE(... fixed [$]$1)
1565                 CF_VERBOSE(... extra $EXTRA_CFLAGS)
1566                 ;;
1567         esac
1568 fi
1569 AC_SUBST(EXTRA_CFLAGS)
1570 ])dnl
1571 dnl ---------------------------------------------------------------------------
1572 dnl CF_FUNC_CURSES_VERSION version: 7 updated: 2017/05/10 18:31:29
1573 dnl ----------------------
1574 dnl Solaris has a data item 'curses_version', which confuses AC_CHECK_FUNCS.
1575 dnl It's a character string "SVR4", not documented.
1576 AC_DEFUN([CF_FUNC_CURSES_VERSION],
1577 [
1578 AC_CACHE_CHECK(for function curses_version, cf_cv_func_curses_version,[
1579 AC_TRY_RUN([
1580 #include <${cf_cv_ncurses_header:-curses.h}>
1581 int main(void)
1582 {
1583         char temp[1024];
1584         sprintf(temp, "%s\n", curses_version());
1585         ${cf_cv_main_return:-return}(0);
1586 }]
1587 ,[cf_cv_func_curses_version=yes]
1588 ,[cf_cv_func_curses_version=no]
1589 ,[cf_cv_func_curses_version=unknown])
1590 rm -f core])
1591 test "$cf_cv_func_curses_version" = yes && AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 if we have curses_version function])
1592 ])
1593 dnl ---------------------------------------------------------------------------
1594 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
1595 dnl ---------------
1596 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1597 dnl "util" library as well.
1598 AC_DEFUN([CF_FUNC_OPENPTY],
1599 [
1600 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1601 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1602         cf_save_LIBS="$LIBS"
1603         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
1604         for cf_header in pty.h libutil.h util.h
1605         do
1606         AC_TRY_LINK([
1607 #include <$cf_header>
1608 ],[
1609         int x = openpty((int *)0, (int *)0, (char *)0,
1610                                    (struct termios *)0, (struct winsize *)0);
1611 ],[
1612                 cf_cv_func_openpty=$cf_header
1613                 break
1614 ],[
1615                 cf_cv_func_openpty=no
1616 ])
1617         done
1618         LIBS="$cf_save_LIBS"
1619 ])
1620 ])dnl
1621 dnl ---------------------------------------------------------------------------
1622 dnl CF_GCC_ATTRIBUTES version: 19 updated: 2020/08/29 09:05:21
1623 dnl -----------------
1624 dnl Test for availability of useful gcc __attribute__ directives to quiet
1625 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1626 dnl to documentation, unrecognized directives cause older compilers to barf.
1627 AC_DEFUN([CF_GCC_ATTRIBUTES],
1628 [
1629 if ( test "$GCC" = yes || test "$GXX" = yes )
1630 then
1631 cat > conftest.i <<EOF
1632 #ifndef GCC_PRINTF
1633 #define GCC_PRINTF 0
1634 #endif
1635 #ifndef GCC_SCANF
1636 #define GCC_SCANF 0
1637 #endif
1638 #ifndef GCC_NORETURN
1639 #define GCC_NORETURN /* nothing */
1640 #endif
1641 #ifndef GCC_UNUSED
1642 #define GCC_UNUSED /* nothing */
1643 #endif
1644 EOF
1645 if test "$GCC" = yes
1646 then
1647         AC_CHECKING([for $CC __attribute__ directives])
1648 cat > conftest.$ac_ext <<EOF
1649 #line __oline__ "${as_me:-configure}"
1650 #include "confdefs.h"
1651 #include "conftest.h"
1652 #include "conftest.i"
1653 #if     GCC_PRINTF
1654 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1655 #else
1656 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1657 #endif
1658 #if     GCC_SCANF
1659 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1660 #else
1661 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1662 #endif
1663 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1664 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1665 extern void foo(void) GCC_NORETURN;
1666 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
1667 EOF
1668         cf_printf_attribute=no
1669         cf_scanf_attribute=no
1670         for cf_attribute in scanf printf unused noreturn
1671         do
1672                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1673                 cf_directive="__attribute__(($cf_attribute))"
1674                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1675
1676                 case $cf_attribute in
1677                 (printf)
1678                         cf_printf_attribute=yes
1679                         cat >conftest.h <<EOF
1680 #define GCC_$cf_ATTRIBUTE 1
1681 EOF
1682                         ;;
1683                 (scanf)
1684                         cf_scanf_attribute=yes
1685                         cat >conftest.h <<EOF
1686 #define GCC_$cf_ATTRIBUTE 1
1687 EOF
1688                         ;;
1689                 (*)
1690                         cat >conftest.h <<EOF
1691 #define GCC_$cf_ATTRIBUTE $cf_directive
1692 EOF
1693                         ;;
1694                 esac
1695
1696                 if AC_TRY_EVAL(ac_compile); then
1697                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1698                         cat conftest.h >>confdefs.h
1699                         case $cf_attribute in
1700                         (noreturn)
1701                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1702                                 ;;
1703                         (printf)
1704                                 cf_value='/* nothing */'
1705                                 if test "$cf_printf_attribute" != no ; then
1706                                         cf_value='__attribute__((format(printf,fmt,var)))'
1707                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1708                                 fi
1709                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1710                                 ;;
1711                         (scanf)
1712                                 cf_value='/* nothing */'
1713                                 if test "$cf_scanf_attribute" != no ; then
1714                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1715                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1716                                 fi
1717                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1718                                 ;;
1719                         (unused)
1720                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1721                                 ;;
1722                         esac
1723                 fi
1724         done
1725 else
1726         fgrep define conftest.i >>confdefs.h
1727 fi
1728 rm -rf conftest*
1729 fi
1730 ])dnl
1731 dnl ---------------------------------------------------------------------------
1732 dnl CF_GCC_VERSION version: 8 updated: 2019/09/07 13:38:36
1733 dnl --------------
1734 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
1735 dnl compatible), attempt to determine if icc/clang is actually used.
1736 AC_DEFUN([CF_GCC_VERSION],[
1737 AC_REQUIRE([AC_PROG_CC])
1738 GCC_VERSION=none
1739 if test "$GCC" = yes ; then
1740         AC_MSG_CHECKING(version of $CC)
1741         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1742         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1743         AC_MSG_RESULT($GCC_VERSION)
1744 fi
1745 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1746 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1747 ])dnl
1748 dnl ---------------------------------------------------------------------------
1749 dnl CF_GCC_WARNINGS version: 38 updated: 2020/08/28 15:08:28
1750 dnl ---------------
1751 dnl Check if the compiler supports useful warning options.  There's a few that
1752 dnl we don't use, simply because they're too noisy:
1753 dnl
1754 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1755 dnl     -Winline (usually not worthwhile)
1756 dnl     -Wredundant-decls (system headers make this too noisy)
1757 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1758 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1759 dnl             is enabled for ncurses using "--enable-const".
1760 dnl     -pedantic
1761 dnl
1762 dnl Parameter:
1763 dnl     $1 is an optional list of gcc warning flags that a particular
1764 dnl             application might want to use, e.g., "no-unused" for
1765 dnl             -Wno-unused
1766 dnl Special:
1767 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1768 dnl
1769 AC_DEFUN([CF_GCC_WARNINGS],
1770 [
1771 AC_REQUIRE([CF_GCC_VERSION])
1772 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
1773 cat > conftest.$ac_ext <<EOF
1774 #line __oline__ "${as_me:-configure}"
1775 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1776 EOF
1777 if test "$INTEL_COMPILER" = yes
1778 then
1779 # The "-wdXXX" options suppress warnings:
1780 # remark #1419: external declaration in primary source file
1781 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1782 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1783 # remark #193: zero used for undefined preprocessing identifier
1784 # remark #593: variable "curs_sb_left_arrow" was set but never used
1785 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1786 # remark #869: parameter "tw" was never referenced
1787 # remark #981: operands are evaluated in unspecified order
1788 # warning #279: controlling expression is constant
1789
1790         AC_CHECKING([for $CC warning options])
1791         cf_save_CFLAGS="$CFLAGS"
1792         EXTRA_CFLAGS="$EXTRA_CFLAGS -Wall"
1793         for cf_opt in \
1794                 wd1419 \
1795                 wd1683 \
1796                 wd1684 \
1797                 wd193 \
1798                 wd593 \
1799                 wd279 \
1800                 wd810 \
1801                 wd869 \
1802                 wd981
1803         do
1804                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1805                 if AC_TRY_EVAL(ac_compile); then
1806                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1807                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1808                 fi
1809         done
1810         CFLAGS="$cf_save_CFLAGS"
1811 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
1812 then
1813         AC_CHECKING([for $CC warning options])
1814         cf_save_CFLAGS="$CFLAGS"
1815         cf_warn_CONST=""
1816         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1817         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1818         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1819         for cf_opt in W Wall \
1820                 Wbad-function-cast \
1821                 Wcast-align \
1822                 Wcast-qual \
1823                 Wdeclaration-after-statement \
1824                 Wextra \
1825                 Winline \
1826                 Wmissing-declarations \
1827                 Wmissing-prototypes \
1828                 Wnested-externs \
1829                 Wpointer-arith \
1830                 Wshadow \
1831                 Wstrict-prototypes \
1832                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
1833         do
1834                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1835                 if AC_TRY_EVAL(ac_compile); then
1836                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1837                         case $cf_opt in
1838                         (Winline)
1839                                 case $GCC_VERSION in
1840                                 ([[34]].*)
1841                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1842                                         continue;;
1843                                 esac
1844                                 ;;
1845                         (Wpointer-arith)
1846                                 case $GCC_VERSION in
1847                                 ([[12]].*)
1848                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1849                                         continue;;
1850                                 esac
1851                                 ;;
1852                         esac
1853                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1854                 fi
1855         done
1856         CFLAGS="$cf_save_CFLAGS"
1857 fi
1858 rm -rf conftest*
1859
1860 AC_SUBST(EXTRA_CFLAGS)
1861 ])dnl
1862 dnl ---------------------------------------------------------------------------
1863 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
1864 dnl ----------------
1865 dnl Check for getopt's variables which are commonly defined in stdlib.h,
1866 dnl unistd.h or (nonstandard) in getopt.h
1867 AC_DEFUN([CF_GETOPT_HEADER],
1868 [
1869 AC_HAVE_HEADERS(unistd.h getopt.h)
1870 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
1871 cf_cv_getopt_header=none
1872 for cf_header in stdio.h stdlib.h unistd.h getopt.h
1873 do
1874 AC_TRY_COMPILE([
1875 #include <$cf_header>],
1876 [int x = optind; char *y = optarg],
1877 [cf_cv_getopt_header=$cf_header
1878  break])
1879 done
1880 ])
1881 if test $cf_cv_getopt_header != none ; then
1882         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
1883 fi
1884 if test $cf_cv_getopt_header = getopt.h ; then
1885         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
1886 fi
1887 ])dnl
1888 dnl ---------------------------------------------------------------------------
1889 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
1890 dnl -------------
1891 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1892 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1893 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1894 dnl since it is interwoven with GNU extensions.
1895 dnl
1896 dnl Well, yes we could work around it...
1897 dnl
1898 dnl Parameters:
1899 dnl     $1 is the nominal value for _XOPEN_SOURCE
1900 AC_DEFUN([CF_GNU_SOURCE],
1901 [
1902 cf_gnu_xopen_source=ifelse($1,,500,$1)
1903
1904 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
1905 AC_TRY_COMPILE([#include <sys/types.h>],[
1906         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
1907                 return 0;
1908         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
1909                 return 0;
1910         #else
1911         #       error not GNU C library
1912         #endif],
1913         [cf_cv_gnu_library=yes],
1914         [cf_cv_gnu_library=no])
1915 ])
1916
1917 if test x$cf_cv_gnu_library = xyes; then
1918
1919         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
1920         # was changed to help a little.  newlib incorporated the change about 4
1921         # years later.
1922         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
1923                 cf_save="$CPPFLAGS"
1924                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
1925                 AC_TRY_COMPILE([#include <sys/types.h>],[
1926                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
1927                                 return 0;
1928                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
1929                                 return 0;
1930                         #else
1931                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
1932                         #endif],
1933                         [cf_cv_gnu_library_219=yes],
1934                         [cf_cv_gnu_library_219=no])
1935                 CPPFLAGS="$cf_save"
1936         ])
1937
1938         if test "x$cf_cv_gnu_library_219" = xyes; then
1939                 cf_save="$CPPFLAGS"
1940                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
1941                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
1942                         AC_TRY_COMPILE([
1943                                 #include <limits.h>
1944                                 #include <sys/types.h>
1945                                 ],[
1946                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
1947                                         return 0;
1948                                 #else
1949                                 #       error GNU C library is too old
1950                                 #endif],
1951                                 [cf_cv_gnu_dftsrc_219=yes],
1952                                 [cf_cv_gnu_dftsrc_219=no])
1953                         ])
1954                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
1955         else
1956                 cf_cv_gnu_dftsrc_219=maybe
1957         fi
1958
1959         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
1960
1961                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1962                 AC_TRY_COMPILE([#include <sys/types.h>],[
1963                         #ifndef _XOPEN_SOURCE
1964                         #error  expected _XOPEN_SOURCE to be defined
1965                         #endif],
1966                         [cf_cv_gnu_source=no],
1967                         [cf_save="$CPPFLAGS"
1968                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
1969                          AC_TRY_COMPILE([#include <sys/types.h>],[
1970                                 #ifdef _XOPEN_SOURCE
1971                                 #error  expected _XOPEN_SOURCE to be undefined
1972                                 #endif],
1973                                 [cf_cv_gnu_source=no],
1974                                 [cf_cv_gnu_source=yes])
1975                         CPPFLAGS="$cf_save"
1976                         ])
1977                 ])
1978
1979                 if test "$cf_cv_gnu_source" = yes
1980                 then
1981                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
1982                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
1983                         AC_TRY_COMPILE([#include <sys/types.h>],[
1984                                 #ifdef _DEFAULT_SOURCE
1985                                 #error  expected _DEFAULT_SOURCE to be undefined
1986                                 #endif],
1987                                 [cf_cv_default_source=no],
1988                                 [cf_cv_default_source=yes])
1989                         ])
1990                         if test "$cf_cv_default_source" = yes
1991                         then
1992                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
1993                         fi
1994                 fi
1995         fi
1996
1997 fi
1998 ])dnl
1999 dnl ---------------------------------------------------------------------------
2000 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
2001 dnl --------------
2002 dnl Construct a search-list of directories for a nonstandard header-file
2003 dnl
2004 dnl Parameters
2005 dnl     $1 = the variable to return as result
2006 dnl     $2 = the package name
2007 AC_DEFUN([CF_HEADER_PATH],
2008 [
2009 $1=
2010
2011 # collect the current set of include-directories from compiler flags
2012 cf_header_path_list=""
2013 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2014         for cf_header_path in $CPPFLAGS $CFLAGS
2015         do
2016                 case $cf_header_path in
2017                 (-I*)
2018                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2019                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2020                         cf_header_path_list="$cf_header_path_list [$]$1"
2021                         ;;
2022                 esac
2023         done
2024 fi
2025
2026 # add the variations for the package we are looking for
2027 CF_SUBDIR_PATH($1,$2,include)
2028
2029 test "$includedir" != NONE && \
2030 test "$includedir" != "/usr/include" && \
2031 test -d "$includedir" && {
2032         test -d $includedir &&    $1="[$]$1 $includedir"
2033         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2034 }
2035
2036 test "$oldincludedir" != NONE && \
2037 test "$oldincludedir" != "/usr/include" && \
2038 test -d "$oldincludedir" && {
2039         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2040         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2041 }
2042
2043 $1="[$]$1 $cf_header_path_list"
2044 ])dnl
2045 dnl ---------------------------------------------------------------------------
2046 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
2047 dnl ---------------
2048 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2049 AC_DEFUN([CF_HELP_MESSAGE],
2050 [CF_ACVERSION_CHECK(2.53,[],[
2051 AC_DIVERT_HELP($1)])dnl
2052 ])dnl
2053 dnl ---------------------------------------------------------------------------
2054 dnl CF_INHERIT_SCRIPT version: 2 updated: 2003/03/01 23:50:42
2055 dnl -----------------
2056 dnl If we do not have a given script, look for it in the parent directory.
2057 AC_DEFUN([CF_INHERIT_SCRIPT],
2058 [
2059 test -f $1 || ( test -f ../$1 && cp ../$1 ./ )
2060 ])dnl
2061 dnl ---------------------------------------------------------------------------
2062 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
2063 dnl ---------------
2064 dnl prompt for/fill-in useful install-program options
2065 AC_DEFUN([CF_INSTALL_OPTS],
2066 [
2067 CF_INSTALL_OPT_S
2068 CF_INSTALL_OPT_P
2069 CF_INSTALL_OPT_O
2070 ])dnl
2071 dnl ---------------------------------------------------------------------------
2072 dnl CF_INSTALL_OPT_O version: 2 updated: 2015/05/15 19:45:35
2073 dnl ----------------
2074 dnl Almost all "install" programs default to the current user's ownership.
2075 dnl Almost - MINIX is an exception.
2076 AC_DEFUN([CF_INSTALL_OPT_O],
2077 [
2078 AC_MSG_CHECKING(if install needs to be told about ownership)
2079 case `$ac_config_guess` in
2080 (*minix)
2081         with_install_o=yes
2082         ;;
2083 (*)
2084         with_install_o=no
2085         ;;
2086 esac
2087
2088 AC_MSG_RESULT($with_install_o)
2089 if test "x$with_install_o" = xyes
2090 then
2091         INSTALL_OPT_O=`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`
2092 else
2093         INSTALL_OPT_O=
2094 fi
2095
2096 AC_SUBST(INSTALL_OPT_O)
2097 ])dnl
2098 dnl ---------------------------------------------------------------------------
2099 dnl CF_INSTALL_OPT_P version: 1 updated: 2018/08/18 12:19:21
2100 dnl ----------------
2101 dnl Some install-programs accept a "-p" option to preserve file modification
2102 dnl timestamps.  That can be useful as an install option, as well as a way to
2103 dnl avoid the need for ranlib after copying a static archive.
2104 AC_DEFUN([CF_INSTALL_OPT_P],
2105 [
2106 : ${INSTALL:=install}
2107 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
2108         rm -rf conftest*
2109         date >conftest.in
2110         mkdir conftest.out
2111         sleep 3
2112         if $INSTALL -p conftest.in conftest.out 2>/dev/null
2113         then
2114                 if test -f conftest.out/conftest.in
2115                 then
2116                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
2117                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
2118                         if test -s conftest.err
2119                         then
2120                                 cf_cv_install_p=no
2121                         else
2122                                 cf_cv_install_p=yes
2123                         fi
2124                 else
2125                         cf_cv_install_p=no
2126                 fi
2127         else
2128                 cf_cv_install_p=no
2129         fi
2130         rm -rf conftest*
2131 ])
2132 ])dnl
2133 dnl ---------------------------------------------------------------------------
2134 dnl CF_INSTALL_OPT_S version: 2 updated: 2018/08/18 12:19:21
2135 dnl ----------------
2136 dnl By default, we should strip executables which are installed, but leave the
2137 dnl ability to suppress that for unit-testing.
2138 AC_DEFUN([CF_INSTALL_OPT_S],
2139 [
2140 AC_MSG_CHECKING(if you want to install stripped executables)
2141 CF_ARG_DISABLE(stripping,
2142         [  --disable-stripping     do not strip (debug info) installed executables],
2143         [with_stripping=no],
2144         [with_stripping=yes])
2145 AC_MSG_RESULT($with_stripping)
2146
2147 if test "$with_stripping" = yes
2148 then
2149         INSTALL_OPT_S="-s"
2150 else
2151         INSTALL_OPT_S=
2152 fi
2153 AC_SUBST(INSTALL_OPT_S)
2154 ])dnl
2155 dnl ---------------------------------------------------------------------------
2156 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
2157 dnl -----------------
2158 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2159 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2160 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2161 dnl
2162 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2163 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2164 dnl the wrappers for gcc and g++ warnings.
2165 dnl
2166 dnl $1 = GCC (default) or GXX
2167 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2168 dnl $3 = CFLAGS (default) or CXXFLAGS
2169 AC_DEFUN([CF_INTEL_COMPILER],[
2170 AC_REQUIRE([AC_CANONICAL_HOST])
2171 ifelse([$2],,INTEL_COMPILER,[$2])=no
2172
2173 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2174         case $host_os in
2175         (linux*|gnu*)
2176                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2177                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2178                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2179                 AC_TRY_COMPILE([],[
2180 #ifdef __INTEL_COMPILER
2181 #else
2182 make an error
2183 #endif
2184 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2185 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
2186 ],[])
2187                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2188                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2189                 ;;
2190         esac
2191 fi
2192 ])dnl
2193 dnl ---------------------------------------------------------------------------
2194 dnl CF_LD_RPATH_OPT version: 8 updated: 2018/08/18 16:36:35
2195 dnl ---------------
2196 dnl For the given system and compiler, find the compiler flags to pass to the
2197 dnl loader to use the "rpath" feature.
2198 AC_DEFUN([CF_LD_RPATH_OPT],
2199 [
2200 AC_REQUIRE([CF_CHECK_CACHE])
2201
2202 LD_RPATH_OPT=
2203 if test "x$cf_cv_enable_rpath" != xno
2204 then
2205         AC_MSG_CHECKING(for an rpath option)
2206         case $cf_cv_system_name in
2207         (irix*)
2208                 if test "$GCC" = yes; then
2209                         LD_RPATH_OPT="-Wl,-rpath,"
2210                 else
2211                         LD_RPATH_OPT="-rpath "
2212                 fi
2213                 ;;
2214         (linux*|gnu*|k*bsd*-gnu|freebsd*)
2215                 LD_RPATH_OPT="-Wl,-rpath,"
2216                 ;;
2217         (openbsd[[2-9]].*|mirbsd*)
2218                 LD_RPATH_OPT="-Wl,-rpath,"
2219                 ;;
2220         (dragonfly*)
2221                 LD_RPATH_OPT="-rpath "
2222                 ;;
2223         (netbsd*)
2224                 LD_RPATH_OPT="-Wl,-rpath,"
2225                 ;;
2226         (osf*|mls+*)
2227                 LD_RPATH_OPT="-rpath "
2228                 ;;
2229         (solaris2*)
2230                 LD_RPATH_OPT="-R"
2231                 ;;
2232         (*)
2233                 ;;
2234         esac
2235         AC_MSG_RESULT($LD_RPATH_OPT)
2236
2237         case "x$LD_RPATH_OPT" in
2238         (x-R*)
2239                 AC_MSG_CHECKING(if we need a space after rpath option)
2240                 cf_save_LIBS="$LIBS"
2241                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
2242                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
2243                 LIBS="$cf_save_LIBS"
2244                 AC_MSG_RESULT($cf_rpath_space)
2245                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
2246                 ;;
2247         esac
2248 fi
2249 ])dnl
2250 dnl ---------------------------------------------------------------------------
2251 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
2252 dnl ---------------
2253 dnl Construct a search-list of directories for a nonstandard library-file
2254 dnl
2255 dnl Parameters
2256 dnl     $1 = the variable to return as result
2257 dnl     $2 = the package name
2258 AC_DEFUN([CF_LIBRARY_PATH],
2259 [
2260 $1=
2261 cf_library_path_list=""
2262 if test -n "${LDFLAGS}${LIBS}" ; then
2263         for cf_library_path in $LDFLAGS $LIBS
2264         do
2265                 case $cf_library_path in
2266                 (-L*)
2267                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
2268                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
2269                         cf_library_path_list="$cf_library_path_list [$]$1"
2270                         ;;
2271                 esac
2272         done
2273 fi
2274
2275 CF_SUBDIR_PATH($1,$2,lib)
2276
2277 $1="$cf_library_path_list [$]$1"
2278 ])dnl
2279 dnl ---------------------------------------------------------------------------
2280 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
2281 dnl ------------
2282 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
2283 dnl a monocase filesystem.
2284 AC_DEFUN([CF_MAKE_TAGS],[
2285 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
2286
2287 AC_CHECK_PROGS(CTAGS, exctags ctags)
2288 AC_CHECK_PROGS(ETAGS, exetags etags)
2289
2290 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
2291
2292 if test "$cf_cv_mixedcase" = yes ; then
2293         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
2294 else
2295         MAKE_UPPER_TAGS=no
2296 fi
2297
2298 if test "$MAKE_UPPER_TAGS" = yes ; then
2299         MAKE_UPPER_TAGS=
2300 else
2301         MAKE_UPPER_TAGS="#"
2302 fi
2303
2304 if test "$MAKE_LOWER_TAGS" = yes ; then
2305         MAKE_LOWER_TAGS=
2306 else
2307         MAKE_LOWER_TAGS="#"
2308 fi
2309
2310 AC_SUBST(CTAGS)
2311 AC_SUBST(ETAGS)
2312
2313 AC_SUBST(MAKE_UPPER_TAGS)
2314 AC_SUBST(MAKE_LOWER_TAGS)
2315 ])dnl
2316 dnl ---------------------------------------------------------------------------
2317 dnl CF_MATH_LIB version: 9 updated: 2017/01/21 11:06:25
2318 dnl -----------
2319 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
2320 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
2321 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
2322 AC_DEFUN([CF_MATH_LIB],
2323 [
2324 AC_CACHE_CHECK(if -lm needed for math functions,
2325         cf_cv_need_libm,[
2326         AC_TRY_LINK([
2327         #include <stdio.h>
2328         #include <stdlib.h>
2329         #include <math.h>
2330         ],
2331         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
2332         [cf_cv_need_libm=no],
2333         [cf_cv_need_libm=yes])])
2334 if test "$cf_cv_need_libm" = yes
2335 then
2336 ifelse($1,,[
2337         CF_ADD_LIB(m)
2338 ],[$1=-lm])
2339 fi
2340 ])
2341 dnl ---------------------------------------------------------------------------
2342 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
2343 dnl ----------------------
2344 dnl Check if the file-system supports mixed-case filenames.  If we're able to
2345 dnl create a lowercase name and see it as uppercase, it doesn't support that.
2346 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
2347 [
2348 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2349 if test "$cross_compiling" = yes ; then
2350         case $target_alias in
2351         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
2352                 cf_cv_mixedcase=no
2353                 ;;
2354         (*)
2355                 cf_cv_mixedcase=yes
2356                 ;;
2357         esac
2358 else
2359         rm -f conftest CONFTEST
2360         echo test >conftest
2361         if test -f CONFTEST ; then
2362                 cf_cv_mixedcase=no
2363         else
2364                 cf_cv_mixedcase=yes
2365         fi
2366         rm -f conftest CONFTEST
2367 fi
2368 ])
2369 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2370 ])dnl
2371 dnl ---------------------------------------------------------------------------
2372 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2373 dnl ----------
2374 dnl Write a debug message to config.log, along with the line number in the
2375 dnl configure script.
2376 AC_DEFUN([CF_MSG_LOG],[
2377 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2378 ])dnl
2379 dnl ---------------------------------------------------------------------------
2380 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2381 dnl -------------------
2382 dnl Check if we can compile with ncurses' header file
2383 dnl $1 is the cache variable to set
2384 dnl $2 is the header-file to include
2385 dnl $3 is the root name (ncurses or ncursesw)
2386 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2387         AC_TRY_COMPILE([
2388 ]ifelse($3,ncursesw,[
2389 #define _XOPEN_SOURCE_EXTENDED
2390 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2391 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2392 ])[
2393 #include <$2>],[
2394 #ifdef NCURSES_VERSION
2395 ]ifelse($3,ncursesw,[
2396 #ifndef WACS_BSSB
2397         make an error
2398 #endif
2399 ])[
2400 printf("%s\n", NCURSES_VERSION);
2401 #else
2402 #ifdef __NCURSES_H
2403 printf("old\n");
2404 #else
2405         make an error
2406 #endif
2407 #endif
2408         ]
2409         ,[$1=$2]
2410         ,[$1=no])
2411 ])dnl
2412 dnl ---------------------------------------------------------------------------
2413 dnl CF_NCURSES_CONFIG version: 23 updated: 2020/02/27 05:21:59
2414 dnl -----------------
2415 dnl Tie together the configure-script macros for ncurses, preferring these in
2416 dnl order:
2417 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2418 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2419 dnl c) just plain libraries
2420 dnl
2421 dnl $1 is the root library name (default: "ncurses")
2422 AC_DEFUN([CF_NCURSES_CONFIG],[
2423 AC_REQUIRE([CF_PKG_CONFIG])
2424 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2425 cf_have_ncuconfig=no
2426
2427 if test "x${PKG_CONFIG:=none}" != xnone; then
2428         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2429         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2430                 AC_MSG_RESULT(yes)
2431
2432                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2433                 cf_have_ncuconfig=unknown
2434
2435                 cf_save_CFLAGS="$CFLAGS"
2436                 cf_save_CPPFLAGS="$CPPFLAGS"
2437                 cf_save_LIBS="$LIBS"
2438
2439                 cf_pkg_cflags=`$PKG_CONFIG --cflags $cf_ncuconfig_root`
2440                 cf_pkg_libs=`$PKG_CONFIG --libs $cf_ncuconfig_root`
2441
2442                 # while -W for passing linker flags is prevalent, it is not "standard".
2443                 # At least one wrapper for c89/c99 (in Apple's xcode) has its own
2444                 # incompatible _and_ non-standard -W option which gives an error.  Work
2445                 # around that pitfall.
2446                 case "x${CC}@@${cf_pkg_libs}@${cf_pkg_cflags}" in
2447                 (x*c[[89]]9@@*-W*)
2448                         CF_ADD_CFLAGS($cf_pkg_cflags)
2449                         CF_ADD_LIBS($cf_pkg_libs)
2450
2451                         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2452                                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2453                                 [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2454                                         int main(void)
2455                                         { char *xx = curses_version(); return (xx == 0); }],
2456                                         [cf_test_ncuconfig=yes],
2457                                         [cf_test_ncuconfig=no],
2458                                         [cf_test_ncuconfig=maybe])],
2459                                 [cf_test_ncuconfig=no])
2460
2461                         CFLAGS="$cf_save_CFLAGS"
2462                         CPPFLAGS="$cf_save_CPPFLAGS"
2463                         LIBS="$cf_save_LIBS"
2464
2465                         if test "x$cf_test_ncuconfig" != xyes; then
2466                                 cf_temp=`echo "x$cf_pkg_cflags" | sed -e s/^x// -e 's/-W[[^     ]]*//g'`
2467                                 cf_pkg_cflags="$cf_temp"
2468                                 cf_temp=`echo "x$cf_pkg_libs" | sed -e s/^x// -e 's/-W[[^       ]]*//g'`
2469                                 cf_pkg_libs="$cf_temp"
2470                         fi
2471                         ;;
2472                 esac
2473
2474                 CF_ADD_CFLAGS($cf_pkg_cflags)
2475                 CF_ADD_LIBS($cf_pkg_libs)
2476
2477                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2478                         [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2479                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2480                                 int main(void)
2481                                 { char *xx = curses_version(); return (xx == 0); }],
2482                                 [cf_have_ncuconfig=yes],
2483                                 [cf_have_ncuconfig=no],
2484                                 [cf_have_ncuconfig=maybe])],
2485                         [cf_have_ncuconfig=no])
2486                 AC_MSG_RESULT($cf_have_ncuconfig)
2487                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
2488                 if test "$cf_have_ncuconfig" != "yes"
2489                 then
2490                         CPPFLAGS="$cf_save_CPPFLAGS"
2491                         LIBS="$cf_save_LIBS"
2492                         NCURSES_CONFIG_PKG=none
2493                 else
2494                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2495                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2496                         CF_TERM_HEADER
2497                 fi
2498
2499         else
2500                 AC_MSG_RESULT(no)
2501                 NCURSES_CONFIG_PKG=none
2502         fi
2503 else
2504         NCURSES_CONFIG_PKG=none
2505 fi
2506
2507 if test "x$cf_have_ncuconfig" = "xno"; then
2508         cf_ncurses_config="${cf_ncuconfig_root}${NCURSES_CONFIG_SUFFIX}-config"; echo "Looking for ${cf_ncurses_config}"
2509
2510         CF_ACVERSION_CHECK(2.52,
2511                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2512                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2513
2514         if test "$NCURSES_CONFIG" != none ; then
2515
2516                 CF_ADD_CFLAGS(`$NCURSES_CONFIG --cflags`)
2517                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2518
2519                 # even with config script, some packages use no-override for curses.h
2520                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2521
2522                 dnl like CF_NCURSES_CPPFLAGS
2523                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2524
2525                 dnl like CF_NCURSES_LIBS
2526                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2527                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2528
2529                 dnl like CF_NCURSES_VERSION
2530                 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2531
2532         else
2533
2534                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2535                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2536
2537         fi
2538 else
2539         NCURSES_CONFIG=none
2540 fi
2541 ])dnl
2542 dnl ---------------------------------------------------------------------------
2543 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
2544 dnl -------------------
2545 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2546 dnl the CPPFLAGS variable so we can include its header.
2547 dnl
2548 dnl The header files may be installed as either curses.h, or ncurses.h (would
2549 dnl be obsolete, except that some packagers prefer this name to distinguish it
2550 dnl from a "native" curses implementation).  If not installed for overwrite,
2551 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2552 dnl /usr/include/ncurses), but someone may have installed overwriting the
2553 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2554 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2555 dnl the header.
2556 dnl
2557 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2558 dnl is already in the include-path, don't even bother with this, since we cannot
2559 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2560 dnl
2561 dnl The optional parameter gives the root name of the library, in case it is
2562 dnl not installed as the default curses library.  That is how the
2563 dnl wide-character version of ncurses is installed.
2564 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2565 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2566
2567 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2568 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2569
2570 test -n "$cf_cv_curses_dir" && \
2571 test "$cf_cv_curses_dir" != "no" && { \
2572   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2573 }
2574
2575 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2576         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2577         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2578         for cf_header in $cf_header_list
2579         do
2580                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2581                 test "$cf_cv_ncurses_h" != no && break
2582         done
2583 ])
2584
2585 CF_NCURSES_HEADER
2586 CF_TERM_HEADER
2587
2588 # some applications need this, but should check for NCURSES_VERSION
2589 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2590
2591 CF_NCURSES_VERSION
2592 ])dnl
2593 dnl ---------------------------------------------------------------------------
2594 dnl CF_NCURSES_EXT_FUNCS version: 4 updated: 2012/10/06 16:39:58
2595 dnl --------------------
2596 dnl Since 2007/11/17, ncurses has defined NCURSES_EXT_FUNCS; earlier versions
2597 dnl may provide these functions.  Define the symbol if it is not defined, and
2598 dnl if it is valid.
2599 AC_DEFUN([CF_NCURSES_EXT_FUNCS],
2600 [
2601 AC_CACHE_CHECK(for ncurses extended functions,cf_cv_ncurses_ext_funcs,[
2602 AC_TRY_COMPILE([
2603 #include <${cf_cv_ncurses_header:-curses.h}>],
2604 [
2605 int x = NCURSES_EXT_FUNCS
2606 ],[cf_cv_ncurses_ext_funcs=defined],[
2607 AC_TRY_LINK([
2608 #include <${cf_cv_ncurses_header:-curses.h}>],
2609 [
2610         (void) assume_default_colors (0, 0);
2611         (void) curses_version ();
2612         (void) define_key (0, 0);
2613         (void) is_term_resized (0, 0);
2614         (void) key_defined (0);
2615         (void) keybound (0, 0);
2616         (void) keyok (0, 0);
2617         (void) resize_term (0, 0);
2618         (void) resizeterm (0, 0);
2619         (void) use_default_colors ();
2620         (void) use_extended_names (0);
2621         (void) wresize (0, 0, 0);],
2622         [cf_cv_ncurses_ext_funcs=yes],
2623         [cf_cv_ncurses_ext_funcs=no])
2624 ])
2625 ])
2626 test "$cf_cv_ncurses_ext_funcs" = yes && AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 if we have ncurses extensions])
2627 ])dnl
2628 dnl ---------------------------------------------------------------------------
2629 dnl CF_NCURSES_HEADER version: 4 updated: 2015/04/15 19:08:48
2630 dnl -----------------
2631 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2632 dnl variations of ncurses' installs.
2633 dnl
2634 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2635 AC_DEFUN([CF_NCURSES_HEADER],[
2636
2637 if test "$cf_cv_ncurses_h" != no ; then
2638         cf_cv_ncurses_header=$cf_cv_ncurses_h
2639 else
2640
2641 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2642         test -n "$verbose" && echo
2643         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2644         test -n "$verbose" && echo search path $cf_search
2645         cf_save2_CPPFLAGS="$CPPFLAGS"
2646         for cf_incdir in $cf_search
2647         do
2648                 CF_ADD_INCDIR($cf_incdir)
2649                 for cf_header in \
2650                         ncurses.h \
2651                         curses.h
2652                 do
2653                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2654                         if test "$cf_cv_ncurses_h2" != no ; then
2655                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2656                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2657                                 break
2658                         fi
2659                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2660                 done
2661                 CPPFLAGS="$cf_save2_CPPFLAGS"
2662                 test "$cf_cv_ncurses_h2" != no && break
2663         done
2664         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2665         ])
2666
2667         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2668         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2669         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2670                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2671         fi
2672         CF_ADD_INCDIR($cf_1st_incdir)
2673
2674 fi
2675
2676 # Set definitions to allow ifdef'ing for ncurses.h
2677
2678 case $cf_cv_ncurses_header in
2679 (*ncurses.h)
2680         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2681         ;;
2682 esac
2683
2684 case $cf_cv_ncurses_header in
2685 (ncurses/curses.h|ncurses/ncurses.h)
2686         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2687         ;;
2688 (ncursesw/curses.h|ncursesw/ncurses.h)
2689         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2690         ;;
2691 esac
2692
2693 ])dnl
2694 dnl ---------------------------------------------------------------------------
2695 dnl CF_NCURSES_LIBS version: 17 updated: 2015/04/15 19:08:48
2696 dnl ---------------
2697 dnl Look for the ncurses library.  This is a little complicated on Linux,
2698 dnl because it may be linked with the gpm (general purpose mouse) library.
2699 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2700 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2701 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2702 dnl and the linker will record a dependency.
2703 dnl
2704 dnl The optional parameter gives the root name of the library, in case it is
2705 dnl not installed as the default curses library.  That is how the
2706 dnl wide-character version of ncurses is installed.
2707 AC_DEFUN([CF_NCURSES_LIBS],
2708 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2709
2710 cf_nculib_root=ifelse($1,,ncurses,$1)
2711         # This works, except for the special case where we find gpm, but
2712         # ncurses is in a nonstandard location via $LIBS, and we really want
2713         # to link gpm.
2714 cf_ncurses_LIBS=""
2715 cf_ncurses_SAVE="$LIBS"
2716 AC_CHECK_LIB(gpm,Gpm_Open,
2717         [AC_CHECK_LIB(gpm,initscr,
2718                 [LIBS="$cf_ncurses_SAVE"],
2719                 [cf_ncurses_LIBS="-lgpm"])])
2720
2721 case $host_os in
2722 (freebsd*)
2723         # This is only necessary if you are linking against an obsolete
2724         # version of ncurses (but it should do no harm, since it's static).
2725         if test "$cf_nculib_root" = ncurses ; then
2726                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2727         fi
2728         ;;
2729 esac
2730
2731 CF_ADD_LIBS($cf_ncurses_LIBS)
2732
2733 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2734 then
2735         CF_ADD_LIBS(-l$cf_nculib_root)
2736 else
2737         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2738                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2739                 [initscr()],
2740                 initscr)
2741 fi
2742
2743 if test -n "$cf_ncurses_LIBS" ; then
2744         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2745         cf_ncurses_SAVE="$LIBS"
2746         for p in $cf_ncurses_LIBS ; do
2747                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2748                 if test "$q" != "$LIBS" ; then
2749                         LIBS="$q"
2750                 fi
2751         done
2752         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2753                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2754                 [AC_MSG_RESULT(yes)],
2755                 [AC_MSG_RESULT(no)
2756                  LIBS="$cf_ncurses_SAVE"])
2757 fi
2758
2759 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2760 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2761 ])dnl
2762 dnl ---------------------------------------------------------------------------
2763 dnl CF_NCURSES_PTHREADS version: 2 updated: 2016/04/22 05:07:41
2764 dnl -------------------
2765 dnl Use this followup check to ensure that we link with pthreads if ncurses
2766 dnl uses it.
2767 AC_DEFUN([CF_NCURSES_PTHREADS],[
2768 : ${cf_nculib_root:=ifelse($1,,ncurses,$1)}
2769 AC_CHECK_LIB($cf_nculib_root,_nc_init_pthreads,
2770         cf_cv_ncurses_pthreads=yes,
2771         cf_cv_ncurses_pthreads=no)
2772 if test "$cf_cv_ncurses_pthreads" = yes
2773 then
2774         CF_ADD_LIBS(-lpthread)
2775 fi
2776 ])dnl
2777 dnl ---------------------------------------------------------------------------
2778 dnl CF_NCURSES_VERSION version: 15 updated: 2017/05/09 19:26:10
2779 dnl ------------------
2780 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2781 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2782 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2783 AC_DEFUN([CF_NCURSES_VERSION],
2784 [
2785 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2786 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2787         cf_cv_ncurses_version=no
2788         cf_tempfile=out$$
2789         rm -f $cf_tempfile
2790         AC_TRY_RUN([
2791 #include <${cf_cv_ncurses_header:-curses.h}>
2792 #include <stdio.h>
2793 int main(void)
2794 {
2795         FILE *fp = fopen("$cf_tempfile", "w");
2796 #ifdef NCURSES_VERSION
2797 # ifdef NCURSES_VERSION_PATCH
2798         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2799 # else
2800         fprintf(fp, "%s\n", NCURSES_VERSION);
2801 # endif
2802 #else
2803 # ifdef __NCURSES_H
2804         fprintf(fp, "old\n");
2805 # else
2806         make an error
2807 # endif
2808 #endif
2809         ${cf_cv_main_return:-return}(0);
2810 }],[
2811         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2812
2813         # This will not work if the preprocessor splits the line after the
2814         # Autoconf token.  The 'unproto' program does that.
2815         cat > conftest.$ac_ext <<EOF
2816 #include <${cf_cv_ncurses_header:-curses.h}>
2817 #undef Autoconf
2818 #ifdef NCURSES_VERSION
2819 Autoconf NCURSES_VERSION
2820 #else
2821 #ifdef __NCURSES_H
2822 Autoconf "old"
2823 #endif
2824 ;
2825 #endif
2826 EOF
2827         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2828         AC_TRY_EVAL(cf_try)
2829         if test -f conftest.out ; then
2830                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2831                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2832                 rm -f conftest.out
2833         fi
2834 ])
2835         rm -f $cf_tempfile
2836 ])
2837 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2838 ])dnl
2839 dnl ---------------------------------------------------------------------------
2840 dnl CF_NCURSES_WRAP_PREFIX version: 1 updated: 2009/03/28 16:08:10
2841 dnl ----------------------
2842 dnl Check for ncurses "wrap-prefix" used for public variables which have been
2843 dnl wrapped with a function to help with concurrency control.
2844 AC_DEFUN([CF_NCURSES_WRAP_PREFIX],
2845 [
2846 AC_MSG_CHECKING(for ncurses wrap-prefix)
2847 AC_ARG_WITH(ncurses-wrap-prefix,
2848         [  --with-ncurses-wrap-prefix naming-prefix for ncurses wrapped-variables],
2849         [NCURSES_WRAP_PREFIX=$withval],
2850         [NCURSES_WRAP_PREFIX=_nc_])
2851 AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
2852
2853 AC_SUBST(NCURSES_WRAP_PREFIX)
2854 ])
2855 dnl ---------------------------------------------------------------------------
2856 dnl CF_NETBSD_FORM_H version: 2 updated: 2012/10/06 16:39:58
2857 dnl ----------------
2858 dnl Check for NetBSD's form.h, which is incompatible with SVr4 and ncurses.
2859 dnl Some workarounds are needed in client programs to allow them to compile.
2860 AC_DEFUN([CF_NETBSD_FORM_H],[
2861 AC_CACHE_CHECK(for NetBSD form.h,cf_cv_netbsd_form_h,[
2862 AC_TRY_COMPILE([
2863 #include <${cf_cv_ncurses_header:-curses.h}>
2864 #include <form.h>
2865 ],[
2866         FORM *form;
2867         int y = current_field(form)->cursor_ypos;
2868         int x = current_field(form)->cursor_xpos;
2869 ],[cf_cv_netbsd_form_h=yes
2870 ],[cf_cv_netbsd_form_h=no])
2871 ])
2872
2873 test "$cf_cv_netbsd_form_h" = yes && AC_DEFINE(HAVE_NETBSD_FORM_H,1,[Define to 1 if we appear to be using NetBSD form.h])
2874 ])dnl
2875 dnl ---------------------------------------------------------------------------
2876 dnl CF_NETBSD_MENU_H version: 2 updated: 2012/10/06 16:39:58
2877 dnl ----------------
2878 dnl Check for NetBSD's menu.h, which is incompatible with SVr4 and ncurses.
2879 dnl Some workarounds are needed in client programs to allow them to compile.
2880 AC_DEFUN([CF_NETBSD_MENU_H],[
2881 AC_CACHE_CHECK(for NetBSD menu.h,cf_cv_netbsd_menu_h,[
2882 AC_TRY_COMPILE([
2883 #include <${cf_cv_ncurses_header:-curses.h}>
2884 #include <menu.h>
2885 ],[
2886         MENU *menu;
2887         int y = menu->max_item_width;
2888 ],[cf_cv_netbsd_menu_h=yes
2889 ],[cf_cv_netbsd_menu_h=no])
2890 ])
2891
2892 test "$cf_cv_netbsd_menu_h" = yes && AC_DEFINE(HAVE_NETBSD_MENU_H,1,[Define to 1 if we appear to be using NetBSD menu.h])
2893 ])dnl
2894 dnl ---------------------------------------------------------------------------
2895 dnl CF_NO_LEAKS_OPTION version: 6 updated: 2015/04/12 15:39:00
2896 dnl ------------------
2897 dnl see CF_WITH_NO_LEAKS
2898 AC_DEFUN([CF_NO_LEAKS_OPTION],[
2899 AC_MSG_CHECKING(if you want to use $1 for testing)
2900 AC_ARG_WITH($1,
2901         [$2],
2902         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
2903          $4
2904 ])
2905         : ${with_cflags:=-g}
2906         : ${with_no_leaks:=yes}
2907          with_$1=yes],
2908         [with_$1=])
2909 AC_MSG_RESULT(${with_$1:-no})
2910
2911 case .$with_cflags in
2912 (.*-g*)
2913         case .$CFLAGS in
2914         (.*-g*)
2915                 ;;
2916         (*)
2917                 CF_ADD_CFLAGS([-g])
2918                 ;;
2919         esac
2920         ;;
2921 esac
2922 ])dnl
2923 dnl ---------------------------------------------------------------------------
2924 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
2925 dnl --------------
2926 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2927 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2928 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2929 dnl delayed evaluation of those symbols.
2930 AC_DEFUN([CF_PATH_SYNTAX],[
2931 if test "x$prefix" != xNONE; then
2932         cf_path_syntax="$prefix"
2933 else
2934         cf_path_syntax="$ac_default_prefix"
2935 fi
2936
2937 case ".[$]$1" in
2938 (.\[$]\(*\)*|.\'*\'*)
2939         ;;
2940 (..|./*|.\\*)
2941         ;;
2942 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
2943         ;;
2944 (.\[$]{*prefix}*|.\[$]{*dir}*)
2945         eval $1="[$]$1"
2946         case ".[$]$1" in
2947         (.NONE/*)
2948                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2949                 ;;
2950         esac
2951         ;;
2952 (.no|.NONE/*)
2953         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2954         ;;
2955 (*)
2956         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2957         ;;
2958 esac
2959 ])dnl
2960 dnl ---------------------------------------------------------------------------
2961 dnl CF_PDCURSES_X11 version: 14 updated: 2018/06/20 20:23:13
2962 dnl ---------------
2963 dnl Configure for PDCurses' X11 library
2964 AC_DEFUN([CF_PDCURSES_X11],[
2965 AC_REQUIRE([CF_X_ATHENA])
2966
2967 CF_ACVERSION_CHECK(2.52,
2968         [AC_CHECK_TOOLS(XCURSES_CONFIG, xcurses-config, none)],
2969         [AC_PATH_PROGS(XCURSES_CONFIG, xcurses-config, none)])
2970
2971 if test "$XCURSES_CONFIG" != none ; then
2972
2973 CF_ADD_CFLAGS(`$XCURSES_CONFIG --cflags`)
2974 CF_ADD_LIBS(`$XCURSES_CONFIG --libs`)
2975
2976 cf_cv_lib_XCurses=yes
2977
2978 else
2979
2980 LDFLAGS="$LDFLAGS $X_LIBS"
2981 CF_CHECK_CFLAGS($X_CFLAGS)
2982 AC_CHECK_LIB(X11,XOpenDisplay,
2983         [CF_ADD_LIBS(-lX11)],,
2984         [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])
2985 AC_CACHE_CHECK(for XCurses library,cf_cv_lib_XCurses,[
2986 CF_ADD_LIBS(-lXCurses)
2987 AC_TRY_LINK([
2988 #include <xcurses.h>
2989 char *XCursesProgramName = "test";
2990 ],[XCursesExit();],
2991 [cf_cv_lib_XCurses=yes],
2992 [cf_cv_lib_XCurses=no])
2993 ])
2994
2995 fi
2996
2997 if test $cf_cv_lib_XCurses = yes ; then
2998         AC_DEFINE(UNIX,1,[Define to 1 if using PDCurses on Unix])
2999         AC_DEFINE(XCURSES,1,[Define to 1 if using PDCurses on Unix])
3000         AC_CHECK_HEADER(xcurses.h, AC_DEFINE(HAVE_XCURSES,1,[Define to 1 if using PDCurses on Unix]))
3001 else
3002         AC_MSG_ERROR(Cannot link with XCurses)
3003 fi
3004 ])dnl
3005 dnl ---------------------------------------------------------------------------
3006 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
3007 dnl -------------
3008 dnl Check for the package-config program, unless disabled by command-line.
3009 AC_DEFUN([CF_PKG_CONFIG],
3010 [
3011 AC_MSG_CHECKING(if you want to use pkg-config)
3012 AC_ARG_WITH(pkg-config,
3013         [  --with-pkg-config{=path} enable/disable use of pkg-config],
3014         [cf_pkg_config=$withval],
3015         [cf_pkg_config=yes])
3016 AC_MSG_RESULT($cf_pkg_config)
3017
3018 case $cf_pkg_config in
3019 (no)
3020         PKG_CONFIG=none
3021         ;;
3022 (yes)
3023         CF_ACVERSION_CHECK(2.52,
3024                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
3025                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
3026         ;;
3027 (*)
3028         PKG_CONFIG=$withval
3029         ;;
3030 esac
3031
3032 test -z "$PKG_CONFIG" && PKG_CONFIG=none
3033 if test "$PKG_CONFIG" != none ; then
3034         CF_PATH_SYNTAX(PKG_CONFIG)
3035 elif test "x$cf_pkg_config" != xno ; then
3036         AC_MSG_WARN(pkg-config is not installed)
3037 fi
3038
3039 AC_SUBST(PKG_CONFIG)
3040 ])dnl
3041 dnl ---------------------------------------------------------------------------
3042 dnl CF_POSIX_C_SOURCE version: 11 updated: 2018/12/31 20:46:17
3043 dnl -----------------
3044 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
3045 dnl
3046 dnl     POSIX.1-1990                            _POSIX_SOURCE
3047 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
3048 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
3049 dnl             Bindings Option
3050 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
3051 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
3052 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
3053 dnl
3054 dnl Parameters:
3055 dnl     $1 is the nominal value for _POSIX_C_SOURCE
3056 AC_DEFUN([CF_POSIX_C_SOURCE],
3057 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
3058
3059 if test "$cf_cv_posix_visible" = no; then
3060
3061 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
3062
3063 cf_save_CFLAGS="$CFLAGS"
3064 cf_save_CPPFLAGS="$CPPFLAGS"
3065
3066 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
3067 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
3068
3069 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
3070         CF_MSG_LOG(if the symbol is already defined go no further)
3071         AC_TRY_COMPILE([#include <sys/types.h>],[
3072 #ifndef _POSIX_C_SOURCE
3073 make an error
3074 #endif],
3075         [cf_cv_posix_c_source=no],
3076         [cf_want_posix_source=no
3077          case .$cf_POSIX_C_SOURCE in
3078          (.[[12]]??*)
3079                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3080                 ;;
3081          (.2)
3082                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3083                 cf_want_posix_source=yes
3084                 ;;
3085          (.*)
3086                 cf_want_posix_source=yes
3087                 ;;
3088          esac
3089          if test "$cf_want_posix_source" = yes ; then
3090                 AC_TRY_COMPILE([#include <sys/types.h>],[
3091 #ifdef _POSIX_SOURCE
3092 make an error
3093 #endif],[],
3094                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
3095          fi
3096          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
3097          CFLAGS="$cf_trim_CFLAGS"
3098          CPPFLAGS="$cf_trim_CPPFLAGS"
3099          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
3100          CF_MSG_LOG(if the second compile does not leave our definition intact error)
3101          AC_TRY_COMPILE([#include <sys/types.h>],[
3102 #ifndef _POSIX_C_SOURCE
3103 make an error
3104 #endif],,
3105          [cf_cv_posix_c_source=no])
3106          CFLAGS="$cf_save_CFLAGS"
3107          CPPFLAGS="$cf_save_CPPFLAGS"
3108         ])
3109 ])
3110
3111 if test "$cf_cv_posix_c_source" != no ; then
3112         CFLAGS="$cf_trim_CFLAGS"
3113         CPPFLAGS="$cf_trim_CPPFLAGS"
3114         CF_ADD_CFLAGS($cf_cv_posix_c_source)
3115 fi
3116
3117 fi # cf_cv_posix_visible
3118
3119 ])dnl
3120 dnl ---------------------------------------------------------------------------
3121 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
3122 dnl ----------------
3123 dnl POSIX documents test-macros which an application may set before any system
3124 dnl headers are included to make features available.
3125 dnl
3126 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
3127 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
3128 dnl recent features visible in the system header files unless the application
3129 dnl overrides the corresponding test-macros.  Doing that introduces portability
3130 dnl problems.
3131 dnl
3132 dnl This macro makes a special check for the symbols used for this, to avoid a
3133 dnl conflicting definition.
3134 AC_DEFUN([CF_POSIX_VISIBLE],
3135 [
3136 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
3137 AC_TRY_COMPILE([#include <stdio.h>],[
3138 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
3139         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
3140         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
3141         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
3142 #error conflicting symbols found
3143 #endif
3144 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
3145 ])
3146 ])dnl
3147 dnl ---------------------------------------------------------------------------
3148 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
3149 dnl ------------
3150 dnl Append definitions and rules for the given programs to the subdirectory
3151 dnl Makefiles, and the recursion rule for the top-level Makefile.
3152 dnl
3153 dnl parameters
3154 dnl     $1 = script to run
3155 dnl     $2 = list of subdirectories
3156 dnl
3157 dnl variables
3158 dnl     $AWK
3159 AC_DEFUN([CF_PRG_RULES],
3160 [
3161 for cf_dir in $2
3162 do
3163         if test ! -d $srcdir/$cf_dir; then
3164                 continue
3165         elif test -f $srcdir/$cf_dir/programs; then
3166                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
3167         fi
3168 done
3169
3170 ])dnl
3171 dnl ---------------------------------------------------------------------------
3172 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
3173 dnl ----------
3174 dnl standard check for CC, plus followup sanity checks
3175 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
3176 AC_DEFUN([CF_PROG_CC],[
3177 CF_ACVERSION_CHECK(2.53,
3178         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
3179          AC_REQUIRE([AC_PROG_CC])],
3180         [])
3181 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
3182 CF_GCC_VERSION
3183 CF_ACVERSION_CHECK(2.52,
3184         [AC_PROG_CC_STDC],
3185         [CF_ANSI_CC_REQD])
3186 CF_CC_ENV_FLAGS
3187 ])dnl
3188 dnl ---------------------------------------------------------------------------
3189 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
3190 dnl ---------------
3191 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
3192 dnl misc/tabset install won't work properly.  Usually this happens only when
3193 dnl using the fallback mkinstalldirs script
3194 AC_DEFUN([CF_PROG_INSTALL],
3195 [AC_PROG_INSTALL
3196 case $INSTALL in
3197 (/*)
3198         ;;
3199 (*)
3200         CF_DIRNAME(cf_dir,$INSTALL)
3201         test -z "$cf_dir" && cf_dir=.
3202         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
3203         ;;
3204 esac
3205 ])dnl
3206 dnl ---------------------------------------------------------------------------
3207 dnl CF_PROG_LINT version: 4 updated: 2019/11/20 18:55:37
3208 dnl ------------
3209 AC_DEFUN([CF_PROG_LINT],
3210 [
3211 AC_CHECK_PROGS(LINT, lint cppcheck splint)
3212 case "x$LINT" in
3213 (xcppcheck|x*/cppcheck)
3214         test -z "$LINT_OPTS" && LINT_OPTS="--enable=all"
3215         ;;
3216 esac
3217 AC_SUBST(LINT_OPTS)
3218 ])dnl
3219 dnl ---------------------------------------------------------------------------
3220 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
3221 dnl ----------------
3222 dnl Remove all -U and -D options that refer to the given symbol from a list
3223 dnl of C compiler options.  This works around the problem that not all
3224 dnl compilers process -U and -D options from left-to-right, so a -U option
3225 dnl cannot be used to cancel the effect of a preceding -D option.
3226 dnl
3227 dnl $1 = target (which could be the same as the source variable)
3228 dnl $2 = source (including '$')
3229 dnl $3 = symbol to remove
3230 define([CF_REMOVE_DEFINE],
3231 [
3232 $1=`echo "$2" | \
3233         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
3234                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
3235 ])dnl
3236 dnl ---------------------------------------------------------------------------
3237 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
3238 dnl ---------------------
3239 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
3240 dnl $1 = name of current macro
3241 define([CF_RESTORE_XTRA_FLAGS],
3242 [
3243 LIBS="$cf_save_LIBS_$1"
3244 CFLAGS="$cf_save_CFLAGS_$1"
3245 CPPFLAGS="$cf_save_CPPFLAGS_$1"
3246 ])dnl
3247 dnl ---------------------------------------------------------------------------
3248 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
3249 dnl -------------
3250 AC_DEFUN([CF_RPATH_HACK],
3251 [
3252 AC_REQUIRE([CF_LD_RPATH_OPT])
3253 AC_MSG_CHECKING(for updated LDFLAGS)
3254 if test -n "$LD_RPATH_OPT" ; then
3255         AC_MSG_RESULT(maybe)
3256
3257         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
3258         cf_rpath_list="/usr/lib /lib"
3259         if test "$cf_ldd_prog" != no
3260         then
3261                 cf_rpath_oops=
3262
3263 AC_TRY_LINK([#include <stdio.h>],
3264                 [printf("Hello");],
3265                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
3266                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
3267
3268                 # If we passed the link-test, but get a "not found" on a given library,
3269                 # this could be due to inept reconfiguration of gcc to make it only
3270                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
3271                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
3272                 # /usr/local libraries.
3273                 if test -n "$cf_rpath_oops"
3274                 then
3275                         for cf_rpath_src in $cf_rpath_oops
3276                         do
3277                                 for cf_rpath_dir in \
3278                                         /usr/local \
3279                                         /usr/pkg \
3280                                         /opt/sfw
3281                                 do
3282                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
3283                                         then
3284                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
3285                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
3286                                                 break
3287                                         fi
3288                                 done
3289                         done
3290                 fi
3291         fi
3292
3293         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
3294
3295         CF_RPATH_HACK_2(LDFLAGS)
3296         CF_RPATH_HACK_2(LIBS)
3297
3298         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
3299 else
3300         AC_MSG_RESULT(no)
3301 fi
3302 AC_SUBST(EXTRA_LDFLAGS)
3303 ])dnl
3304 dnl ---------------------------------------------------------------------------
3305 dnl CF_RPATH_HACK_2 version: 7 updated: 2015/04/12 15:39:00
3306 dnl ---------------
3307 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
3308 dnl EXTRA_LDFLAGS for each -L option found.
3309 dnl
3310 dnl $cf_rpath_list contains a list of directories to ignore.
3311 dnl
3312 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
3313 dnl      but LIBS often has misplaced -L options.
3314 AC_DEFUN([CF_RPATH_HACK_2],
3315 [
3316 CF_VERBOSE(...checking $1 [$]$1)
3317
3318 cf_rpath_dst=
3319 for cf_rpath_src in [$]$1
3320 do
3321         case $cf_rpath_src in
3322         (-L*)
3323
3324                 # check if this refers to a directory which we will ignore
3325                 cf_rpath_skip=no
3326                 if test -n "$cf_rpath_list"
3327                 then
3328                         for cf_rpath_item in $cf_rpath_list
3329                         do
3330                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
3331                                 then
3332                                         cf_rpath_skip=yes
3333                                         break
3334                                 fi
3335                         done
3336                 fi
3337
3338                 if test "$cf_rpath_skip" = no
3339                 then
3340                         # transform the option
3341                         if test "$LD_RPATH_OPT" = "-R " ; then
3342                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
3343                         else
3344                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
3345                         fi
3346
3347                         # if we have not already added this, add it now
3348                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
3349                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
3350                         then
3351                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
3352                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
3353                         fi
3354                 fi
3355                 ;;
3356         esac
3357         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
3358 done
3359 $1=$cf_rpath_dst
3360
3361 CF_VERBOSE(...checked $1 [$]$1)
3362 AC_SUBST(EXTRA_LDFLAGS)
3363 ])dnl
3364 dnl ---------------------------------------------------------------------------
3365 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
3366 dnl ------------------
3367 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
3368 dnl and libraries which do not update those variables.
3369 dnl
3370 dnl $1 = name of current macro
3371 define([CF_SAVE_XTRA_FLAGS],
3372 [
3373 cf_save_LIBS_$1="$LIBS"
3374 cf_save_CFLAGS_$1="$CFLAGS"
3375 cf_save_CPPFLAGS_$1="$CPPFLAGS"
3376 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
3377 for cf_X_CFLAGS in $X_CFLAGS
3378 do
3379         case "x$cf_X_CFLAGS" in
3380         x-[[IUD]]*)
3381                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
3382                 ;;
3383         *)
3384                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
3385                 ;;
3386         esac
3387 done
3388 ])dnl
3389 dnl ---------------------------------------------------------------------------
3390 dnl CF_SIGWINCH version: 3 updated: 2020/03/10 18:53:47
3391 dnl -----------
3392 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
3393 dnl programs need this test).
3394 dnl
3395 dnl This is really a Mac OS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
3396 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
3397 dnl winsize declaration is left alone - we may revisit this if Apple choose to
3398 dnl break that part of the interface as well.
3399 AC_DEFUN([CF_SIGWINCH],
3400 [
3401 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
3402         AC_TRY_COMPILE([
3403 #include <sys/types.h>
3404 #include <sys/signal.h>
3405 ],[int x = SIGWINCH; (void)x],
3406         [cf_cv_define_sigwinch=yes],
3407         [AC_TRY_COMPILE([
3408 #undef _XOPEN_SOURCE
3409 #undef _POSIX_SOURCE
3410 #undef _POSIX_C_SOURCE
3411 #include <sys/types.h>
3412 #include <sys/signal.h>
3413 ],[int x = SIGWINCH; (void)x],
3414         [cf_cv_define_sigwinch=maybe],
3415         [cf_cv_define_sigwinch=no])
3416 ])
3417 ])
3418
3419 if test "$cf_cv_define_sigwinch" = maybe ; then
3420 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
3421 cf_cv_fixup_sigwinch=unknown
3422 cf_sigwinch=32
3423 while test $cf_sigwinch != 1
3424 do
3425         AC_TRY_COMPILE([
3426 #undef _XOPEN_SOURCE
3427 #undef _POSIX_SOURCE
3428 #undef _POSIX_C_SOURCE
3429 #include <sys/types.h>
3430 #include <sys/signal.h>
3431 ],[
3432 #if SIGWINCH != $cf_sigwinch
3433 make an error
3434 #endif
3435 int x = SIGWINCH; (void)x],
3436         [cf_cv_fixup_sigwinch=$cf_sigwinch
3437          break])
3438
3439 cf_sigwinch=`expr $cf_sigwinch - 1`
3440 done
3441 ])
3442
3443         if test "$cf_cv_fixup_sigwinch" != unknown ; then
3444                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
3445         fi
3446 fi
3447 ])dnl
3448 dnl ---------------------------------------------------------------------------
3449 dnl CF_SIG_ATOMIC_T version: 5 updated: 2020/03/10 18:53:47
3450 dnl ---------------
3451 dnl signal handler, but there are some gcc dependencies in that recommendation.
3452 dnl Try anyway.
3453 AC_DEFUN([CF_SIG_ATOMIC_T],
3454 [
3455 AC_MSG_CHECKING(for signal global datatype)
3456 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
3457         for cf_type in \
3458                 "volatile sig_atomic_t" \
3459                 "sig_atomic_t" \
3460                 "int"
3461         do
3462         AC_TRY_COMPILE([
3463 #include <sys/types.h>
3464 #include <signal.h>
3465 #include <stdio.h>
3466
3467 extern $cf_type x;
3468 $cf_type x;
3469 static void handler(int sig)
3470 {
3471         (void)sig;
3472         x = 5;
3473 }],
3474                 [signal(SIGINT, handler);
3475                  x = 1],
3476                 [cf_cv_sig_atomic_t=$cf_type],
3477                 [cf_cv_sig_atomic_t=no])
3478                 test "$cf_cv_sig_atomic_t" != no && break
3479         done
3480         ])
3481 AC_MSG_RESULT($cf_cv_sig_atomic_t)
3482 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
3483 ])dnl
3484 dnl ---------------------------------------------------------------------------
3485 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
3486 dnl --------------
3487 dnl Construct a search-list for a nonstandard header/lib-file
3488 dnl     $1 = the variable to return as result
3489 dnl     $2 = the package name
3490 dnl     $3 = the subdirectory, e.g., bin, include or lib
3491 AC_DEFUN([CF_SUBDIR_PATH],
3492 [
3493 $1=
3494
3495 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
3496
3497 for cf_subdir_prefix in \
3498         /usr \
3499         /usr/local \
3500         /usr/pkg \
3501         /opt \
3502         /opt/local \
3503         [$]HOME
3504 do
3505         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
3506 done
3507 ])dnl
3508 dnl ---------------------------------------------------------------------------
3509 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
3510 dnl ------------------
3511 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
3512 dnl older SCO configurations.
3513 AC_DEFUN([CF_SYS_TIME_SELECT],
3514 [
3515 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
3516 AC_CACHE_VAL(cf_cv_sys_time_select,[
3517 AC_TRY_COMPILE([
3518 #include <sys/types.h>
3519 #ifdef HAVE_SYS_TIME_H
3520 #include <sys/time.h>
3521 #endif
3522 #ifdef HAVE_SYS_SELECT_H
3523 #include <sys/select.h>
3524 #endif
3525 ],[],[cf_cv_sys_time_select=yes],
3526          [cf_cv_sys_time_select=no])
3527          ])
3528 AC_MSG_RESULT($cf_cv_sys_time_select)
3529 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
3530 ])dnl
3531 dnl ---------------------------------------------------------------------------
3532 dnl CF_TERM_HEADER version: 5 updated: 2020/03/19 20:23:48
3533 dnl --------------
3534 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
3535 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
3536 dnl but some packagers change this, breaking various applications.
3537 AC_DEFUN([CF_TERM_HEADER],[
3538 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
3539 case ${cf_cv_ncurses_header} in
3540 (*/ncurses.h|*/ncursesw.h)
3541         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
3542         ;;
3543 (*)
3544         cf_term_header=term.h
3545         ;;
3546 esac
3547
3548 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
3549 do
3550 AC_TRY_COMPILE([#include <stdio.h>
3551 #include <${cf_cv_ncurses_header:-curses.h}>
3552 #include <$cf_test>
3553 ],[int x = auto_left_margin; (void)x],[
3554         cf_cv_term_header="$cf_test"],[
3555         cf_cv_term_header=unknown
3556         ])
3557         test "$cf_cv_term_header" != unknown && break
3558 done
3559 ])
3560
3561 # Set definitions to allow ifdef'ing to accommodate subdirectories
3562
3563 case $cf_cv_term_header in
3564 (*term.h)
3565         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
3566         ;;
3567 esac
3568
3569 case $cf_cv_term_header in
3570 (ncurses/term.h)
3571         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
3572         ;;
3573 (ncursesw/term.h)
3574         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
3575         ;;
3576 esac
3577 ])dnl
3578 dnl ---------------------------------------------------------------------------
3579 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
3580 dnl ---------------
3581 dnl Define a top_builddir symbol, for applications that need an absolute path.
3582 AC_DEFUN([CF_TOP_BUILDDIR],
3583 [
3584 top_builddir=ifelse($1,,`pwd`,$1)
3585 AC_SUBST(top_builddir)
3586 ])dnl
3587 dnl ---------------------------------------------------------------------------
3588 dnl CF_TPUTS_PROTO version: 3 updated: 2015/04/17 21:26:14
3589 dnl --------------
3590 dnl Check for type of function-pointer passed to tputs.  Some old
3591 dnl implementations used functions that had different prototypes, making it
3592 dnl hard to compile portable programs using tputs.
3593 AC_DEFUN([CF_TPUTS_PROTO],[
3594 CF_CURSES_FUNCS(tputs)
3595 if test x$cf_cv_func_tputs = xyes
3596 then
3597         cf_done=no
3598         for cf_arg in int char
3599         do
3600                 for cf_ret in int void
3601                 do
3602                         if test $cf_ret = void
3603                         then
3604                                 cf_return="/* nothing */"
3605                         else
3606                                 cf_return="return value"
3607                         fi
3608                         AC_TRY_COMPILE([
3609 #include <${cf_cv_ncurses_header:-curses.h}>
3610 #include <$cf_cv_term_header>
3611
3612 static $cf_ret outc($cf_arg value) { $cf_return; }
3613 ],[
3614         tputs("hello", 0, outc);
3615         ${cf_cv_main_return:-return}(0);
3616 ],[
3617                 CF_VERBOSE([prototype $cf_ret func($cf_arg value)])
3618                 cat >>confdefs.h <<EOF
3619 #define TPUTS_ARG               $cf_arg
3620 #define TPUTS_PROTO(func,value) $cf_ret func(TPUTS_ARG value)
3621 #define TPUTS_RETURN(value)     $cf_return
3622 EOF
3623                 cf_done=yes
3624                 break
3625 ])
3626                 done
3627                 test $cf_done = yes && break
3628         done
3629 fi
3630 ])dnl
3631 dnl ---------------------------------------------------------------------------
3632 dnl CF_TRIM_X_LIBS version: 3 updated: 2015/04/12 15:39:00
3633 dnl --------------
3634 dnl Trim extra base X libraries added as a workaround for inconsistent library
3635 dnl dependencies returned by "new" pkg-config files.
3636 AC_DEFUN([CF_TRIM_X_LIBS],[
3637         for cf_trim_lib in Xmu Xt X11
3638         do
3639                 case "$LIBS" in
3640                 (*-l$cf_trim_lib\ *-l$cf_trim_lib*)
3641                         LIBS=`echo "$LIBS " | sed -e 's/  / /g' -e 's%-l'"$cf_trim_lib"' %%' -e 's/ $//'`
3642                         CF_VERBOSE(..trimmed $LIBS)
3643                         ;;
3644                 esac
3645         done
3646 ])
3647 dnl ---------------------------------------------------------------------------
3648 dnl CF_TRY_PKG_CONFIG version: 5 updated: 2013/07/06 21:27:06
3649 dnl -----------------
3650 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
3651 dnl available in that form.
3652 dnl
3653 dnl $1 = package name
3654 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
3655 dnl $3 = logic to use if pkg-config does not have the package
3656 AC_DEFUN([CF_TRY_PKG_CONFIG],[
3657 AC_REQUIRE([CF_PKG_CONFIG])
3658
3659 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists $1; then
3660         CF_VERBOSE(found package $1)
3661         cf_pkgconfig_incs="`$PKG_CONFIG --cflags $1 2>/dev/null`"
3662         cf_pkgconfig_libs="`$PKG_CONFIG --libs   $1 2>/dev/null`"
3663         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
3664         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
3665         CF_ADD_CFLAGS($cf_pkgconfig_incs)
3666         CF_ADD_LIBS($cf_pkgconfig_libs)
3667         ifelse([$2],,:,[$2])
3668 else
3669         cf_pkgconfig_incs=
3670         cf_pkgconfig_libs=
3671         ifelse([$3],,:,[$3])
3672 fi
3673 ])
3674 dnl ---------------------------------------------------------------------------
3675 dnl CF_TRY_XOPEN_SOURCE version: 2 updated: 2018/06/20 20:23:13
3676 dnl -------------------
3677 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
3678 dnl can define it successfully.
3679 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
3680 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
3681         AC_TRY_COMPILE([
3682 #include <stdlib.h>
3683 #include <string.h>
3684 #include <sys/types.h>
3685 ],[
3686 #ifndef _XOPEN_SOURCE
3687 make an error
3688 #endif],
3689         [cf_cv_xopen_source=no],
3690         [cf_save="$CPPFLAGS"
3691          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
3692          AC_TRY_COMPILE([
3693 #include <stdlib.h>
3694 #include <string.h>
3695 #include <sys/types.h>
3696 ],[
3697 #ifdef _XOPEN_SOURCE
3698 make an error
3699 #endif],
3700         [cf_cv_xopen_source=no],
3701         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
3702         CPPFLAGS="$cf_save"
3703         ])
3704 ])
3705
3706 if test "$cf_cv_xopen_source" != no ; then
3707         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
3708         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
3709         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
3710         CF_ADD_CFLAGS($cf_temp_xopen_source)
3711 fi
3712 ])
3713 dnl ---------------------------------------------------------------------------
3714 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
3715 dnl --------
3716 dnl Make an uppercase version of a variable
3717 dnl $1=uppercase($2)
3718 AC_DEFUN([CF_UPPER],
3719 [
3720 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
3721 ])dnl
3722 dnl ---------------------------------------------------------------------------
3723 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
3724 dnl -----------
3725 dnl Check for multibyte support, and if not found, utf8 compatibility library
3726 AC_DEFUN([CF_UTF8_LIB],
3727 [
3728 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
3729         cf_save_LIBS="$LIBS"
3730         AC_TRY_LINK([
3731 #include <stdlib.h>],[putwc(0,0);],
3732         [cf_cv_utf8_lib=yes],
3733         [CF_FIND_LINKAGE([
3734 #include <libutf8.h>],[putwc(0,0);],utf8,
3735                 [cf_cv_utf8_lib=add-on],
3736                 [cf_cv_utf8_lib=no])
3737 ])])
3738
3739 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
3740 # ncurses/ncursesw:
3741 if test "$cf_cv_utf8_lib" = "add-on" ; then
3742         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
3743         CF_ADD_INCDIR($cf_cv_header_path_utf8)
3744         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
3745         CF_ADD_LIBS($cf_cv_library_file_utf8)
3746 fi
3747 ])dnl
3748 dnl ---------------------------------------------------------------------------
3749 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
3750 dnl ----------
3751 dnl Use AC_VERBOSE w/o the warnings
3752 AC_DEFUN([CF_VERBOSE],
3753 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
3754 CF_MSG_LOG([$1])
3755 ])dnl
3756 dnl ---------------------------------------------------------------------------
3757 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
3758 dnl -------------
3759 dnl Check if type wide-character type $1 is declared, and if so, which header
3760 dnl file is needed.  The second parameter is used to set a shell variable when
3761 dnl the type is not found.  The first parameter sets a shell variable for the
3762 dnl opposite sense.
3763 AC_DEFUN([CF_WCHAR_TYPE],
3764 [
3765 # This is needed on Tru64 5.0 to declare $1
3766 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
3767 AC_TRY_COMPILE([
3768 #include <stdlib.h>
3769 #include <stdarg.h>
3770 #include <stdio.h>
3771 #ifdef HAVE_LIBUTF8_H
3772 #include <libutf8.h>
3773 #endif],
3774         [$1 state],
3775         [cf_cv_$1=no],
3776         [AC_TRY_COMPILE([
3777 #include <stdlib.h>
3778 #include <stdarg.h>
3779 #include <stdio.h>
3780 #include <wchar.h>
3781 #ifdef HAVE_LIBUTF8_H
3782 #include <libutf8.h>
3783 #endif],
3784         [$1 value],
3785         [cf_cv_$1=yes],
3786         [cf_cv_$1=unknown])])])
3787
3788 if test "$cf_cv_$1" = yes ; then
3789         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
3790         NEED_WCHAR_H=1
3791 fi
3792
3793 ifelse([$2],,,[
3794 # if we do not find $1 in either place, use substitution to provide a fallback.
3795 if test "$cf_cv_$1" = unknown ; then
3796         $2=1
3797 fi
3798 ])
3799 ifelse($3,,,[
3800 # if we find $1 in either place, use substitution to provide a fallback.
3801 if test "$cf_cv_$1" != unknown ; then
3802         $3=1
3803 fi
3804 ])
3805 ])dnl
3806 dnl ---------------------------------------------------------------------------
3807 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3808 dnl ------------------
3809 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3810 dnl libraries.
3811 AC_DEFUN([CF_WITH_CURSES_DIR],[
3812
3813 AC_MSG_CHECKING(for specific curses-directory)
3814 AC_ARG_WITH(curses-dir,
3815         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3816         [cf_cv_curses_dir=$withval],
3817         [cf_cv_curses_dir=no])
3818 AC_MSG_RESULT($cf_cv_curses_dir)
3819
3820 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3821 then
3822         CF_PATH_SYNTAX(withval)
3823         if test -d "$cf_cv_curses_dir"
3824         then
3825                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3826                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3827         fi
3828 fi
3829 ])dnl
3830 dnl ---------------------------------------------------------------------------
3831 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
3832 dnl ----------------
3833 dnl Configure-option for dbmalloc.  The optional parameter is used to override
3834 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
3835 AC_DEFUN([CF_WITH_DBMALLOC],[
3836 CF_NO_LEAKS_OPTION(dbmalloc,
3837         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
3838         [USE_DBMALLOC])
3839
3840 if test "$with_dbmalloc" = yes ; then
3841         AC_CHECK_HEADER(dbmalloc.h,
3842                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
3843 fi
3844 ])dnl
3845 dnl ---------------------------------------------------------------------------
3846 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
3847 dnl ---------------
3848 dnl Configure-option for dmalloc.  The optional parameter is used to override
3849 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
3850 AC_DEFUN([CF_WITH_DMALLOC],[
3851 CF_NO_LEAKS_OPTION(dmalloc,
3852         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
3853         [USE_DMALLOC])
3854
3855 if test "$with_dmalloc" = yes ; then
3856         AC_CHECK_HEADER(dmalloc.h,
3857                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
3858 fi
3859 ])dnl
3860 dnl ---------------------------------------------------------------------------
3861 dnl CF_WITH_LIB_BASENAME version: 1 updated: 2020/03/07 20:05:14
3862 dnl --------------------
3863 dnl Allow for overriding the basename of a library, i.e., the part to which
3864 dnl prefixes/suffixes are attached.
3865 dnl
3866 dnl $1 = variable to set
3867 dnl $2 = option name
3868 dnl $3 = default basename for library, if omitted use $2
3869 AC_DEFUN([CF_WITH_LIB_BASENAME],
3870 [
3871 AC_MSG_CHECKING(for desired basename for $2 library)
3872 AC_ARG_WITH($2-libname,
3873         [  --with-$2-libname=XXX override ifelse($3,,$2,$3) basename of library],
3874         [with_lib_basename=$withval],
3875         [with_lib_basename=ifelse($3,,$2,$3)])
3876 $1="$with_lib_basename"
3877
3878 case "x[$]$1" in
3879 (x|xno|xnone|xyes)
3880         $1=ifelse($3,,$2,$3)
3881         ;;
3882 (*)
3883         ;;
3884 esac
3885
3886 AC_MSG_RESULT([$]$1)
3887 AC_SUBST($1)
3888 ])dnl
3889 dnl ---------------------------------------------------------------------------
3890 dnl CF_WITH_NCURSES_ETC version: 5 updated: 2016/02/20 19:23:20
3891 dnl -------------------
3892 dnl Use this macro for programs which use any variant of "curses", e.g.,
3893 dnl "ncurses", and "PDCurses".  Programs that can use curses and some unrelated
3894 dnl library (such as slang) should use a "--with-screen=XXX" option.
3895 dnl
3896 dnl This does not use AC_DEFUN, because that would tell autoconf to run each
3897 dnl of the macros inside this one - before this macro.
3898 define([CF_WITH_NCURSES_ETC],[
3899 CF_WITH_CURSES_DIR
3900
3901 cf_cv_screen=curses
3902
3903 AC_MSG_CHECKING(for specified curses library type)
3904 AC_ARG_WITH(screen,
3905         [  --with-screen=XXX       use specified curses-libraries],
3906         [cf_cv_screen=$withval],[
3907
3908 AC_ARG_WITH(ncursesw,
3909         [  --with-ncursesw         use wide ncurses-libraries],
3910         [cf_cv_screen=ncursesw],[
3911
3912 AC_ARG_WITH(ncurses,
3913         [  --with-ncurses          use ncurses-libraries],
3914         [cf_cv_screen=ncurses],[
3915
3916 AC_ARG_WITH(pdcurses,
3917         [  --with-pdcurses         compile/link with pdcurses X11 library],
3918         [cf_cv_screen=pdcurses],[
3919
3920 AC_ARG_WITH(curses-colr,
3921         [  --with-curses-colr      compile/link with HPUX 10.x color-curses],
3922         [cf_cv_screen=curses_colr],[
3923
3924 AC_ARG_WITH(curses-5lib,
3925         [  --with-curses-5lib      compile/link with SunOS 5lib curses],
3926         [cf_cv_screen=curses_5lib])])])])])])
3927
3928 AC_MSG_RESULT($cf_cv_screen)
3929
3930 case $cf_cv_screen in
3931 (curses|curses_*)
3932         CF_CURSES_CONFIG
3933         ;;
3934 (ncursesw*)
3935         CF_UTF8_LIB
3936         CF_NCURSES_CONFIG($cf_cv_screen)
3937         ;;
3938 (ncurses*)
3939         CF_NCURSES_CONFIG($cf_cv_screen)
3940         ;;
3941 (pdcurses)
3942         CF_PDCURSES_X11
3943         ;;
3944 (*)
3945         AC_MSG_ERROR(unexpected screen-value: $cf_cv_screen)
3946         ;;
3947 esac
3948
3949 CF_NCURSES_PTHREADS($cf_cv_screen)
3950
3951 ])dnl
3952 dnl ---------------------------------------------------------------------------
3953 dnl CF_WITH_SCREEN_PDCURSES version: 1 updated: 2020/08/28 16:56:27
3954 dnl -----------------------
3955 dnl Call this macro before CF_ENABLE_WARNINGS for configure scripts which use
3956 dnl the "--with-screen=pdcurses" selection.  Doing that allows the configure
3957 dnl script to search for the X11/Xt header files to declare (or not) the
3958 dnl symbol needed to enable "const" in those header files.  If that configure
3959 dnl option is not used, then those checks are unnecessary.
3960 AC_DEFUN([CF_WITH_SCREEN_PDCURSES],[
3961 AC_PROVIDE([AC_PATH_XTRA])
3962 AC_PROVIDE([AC_PATH_X])
3963 if test -n "$with_screen" && test "x$with_screen" = "xpdcurses"
3964 then
3965         AC_PATH_X
3966         AC_PATH_XTRA
3967 fi
3968 ])dnl
3969 dnl ---------------------------------------------------------------------------
3970 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
3971 dnl ----------------
3972 AC_DEFUN([CF_WITH_VALGRIND],[
3973 CF_NO_LEAKS_OPTION(valgrind,
3974         [  --with-valgrind         test: use valgrind],
3975         [USE_VALGRIND])
3976 ])dnl
3977 dnl ---------------------------------------------------------------------------
3978 dnl CF_WITH_X11_RGB version: 2 updated: 2019/12/31 08:53:54
3979 dnl ---------------
3980 dnl Handle configure option "--with-x11-rgb", setting these shell
3981 dnl variables:
3982 dnl
3983 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
3984 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
3985 dnl
3986 dnl Most Linux's use this:
3987 dnl     /usr/share/X11/rgb.txt
3988 dnl Debian uses this:
3989 dnl     /etc/X11/rgb.txt
3990 dnl DragonFlyBSD ports uses this:
3991 dnl     /usr/pkg/lib/X11/rgb.txt
3992 dnl FreeBSD ports use these:
3993 dnl     /usr/local/lib/X11/rgb.txt
3994 dnl     /usr/local/share/X11/rgb.txt
3995 dnl Mandriva has these:
3996 dnl     /usr/lib/X11/rgb.txt
3997 dnl     /usr/lib64/X11/rgb.txt
3998 dnl NetBSD has these
3999 dnl     /usr/X11R7/lib/X11/rgb.txt
4000 dnl OpenSolaris uses
4001 dnl     32-bit:
4002 dnl     /usr/X11/etc/X11/rgb.txt
4003 dnl     /usr/X11/share/X11/rgb.txt
4004 dnl     /usr/X11/lib/X11/rgb.txt
4005 dnl OSX uses
4006 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
4007 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
4008 dnl     64-bit:
4009 dnl     /usr/X11/etc/X11/rgb.txt
4010 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
4011 dnl     /usr/X11/lib/amd64/X11/rgb.txt
4012 dnl Solaris10 uses (in this order):
4013 dnl     /usr/openwin/lib/X11/rgb.txt
4014 dnl     /usr/X11/lib/X11/rgb.txt
4015 AC_DEFUN([CF_WITH_X11_RGB],[
4016 AC_MSG_CHECKING(for X11 rgb file)
4017 AC_ARG_WITH(x11-rgb,
4018         [  --with-x11-rgb=FILE   file containing X11 rgb information (EPREFIX/lib/X11/rgb.txt)],
4019         [RGB_PATH=$withval],
4020         [RGB_PATH=auto])
4021
4022 if test "x[$]RGB_PATH" = xauto
4023 then
4024         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
4025         for cf_path in \
4026                 /opt/local/share/X11/rgb.txt \
4027                 /opt/X11/share/X11/rgb.txt \
4028                 /usr/share/X11/rgb.txt \
4029                 /usr/X11/share/X11/rgb.txt \
4030                 /usr/X11/lib/X11/rgb.txt \
4031                 /usr/lib/X11/rgb.txt \
4032                 /etc/X11/rgb.txt \
4033                 /usr/pkg/lib/X11/rgb.txt \
4034                 /usr/X11R7/lib/X11/rgb.txt \
4035                 /usr/X11R6/lib/X11/rgb.txt \
4036                 /usr/X11R5/lib/X11/rgb.txt \
4037                 /usr/X11R4/lib/X11/rgb.txt \
4038                 /usr/local/lib/X11/rgb.txt \
4039                 /usr/local/share/X11/rgb.txt \
4040                 /usr/lib64/X11/rgb.txt
4041         do
4042                 if test -f "$cf_path" ; then
4043                         RGB_PATH="$cf_path"
4044                         break
4045                 fi
4046         done
4047 else
4048         cf_path=$RGB_PATH
4049         CF_PATH_SYNTAX(cf_path)
4050 fi
4051
4052 AC_MSG_RESULT($RGB_PATH)
4053 AC_SUBST(RGB_PATH)
4054 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path",[Define to the full pathname of rgb.txt])
4055
4056 no_x11_rgb=
4057 if test "$RGB_PATH" = no
4058 then
4059         no_x11_rgb="#"
4060 fi
4061 AC_SUBST(no_x11_rgb)
4062 ])dnl
4063 dnl ---------------------------------------------------------------------------
4064 dnl CF_XOPEN_CURSES version: 15 updated: 2020/03/19 20:23:48
4065 dnl ---------------
4066 dnl Test if we should define X/Open source for curses, needed on Digital Unix
4067 dnl 4.x, to see the extended functions, but breaks on IRIX 6.x.
4068 dnl
4069 dnl The getbegyx() check is needed for HPUX, which omits legacy macros such
4070 dnl as getbegy().  The latter is better design, but the former is standard.
4071 AC_DEFUN([CF_XOPEN_CURSES],
4072 [
4073 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
4074 AC_CACHE_CHECK(definition to turn on extended curses functions,cf_cv_need_xopen_extension,[
4075 cf_cv_need_xopen_extension=unknown
4076 AC_TRY_LINK([
4077 #include <stdlib.h>
4078 #include <${cf_cv_ncurses_header:-curses.h}>],[
4079 #if defined(NCURSES_VERSION_PATCH)
4080 #if (NCURSES_VERSION_PATCH < 20100501) && (NCURSES_VERSION_PATCH >= 20100403)
4081         make an error
4082 #endif
4083 #endif
4084 #ifdef NCURSES_VERSION
4085         cchar_t check;
4086         int check2 = curs_set((int)sizeof(check));
4087 #endif
4088         long x = winnstr(stdscr, "", 0);
4089         int x1, y1;
4090 #ifdef NCURSES_VERSION
4091         (void)check2;
4092 #endif
4093         getbegyx(stdscr, y1, x1);
4094         (void)x;
4095         (void)y1;
4096         (void)x1;
4097         ],
4098         [cf_cv_need_xopen_extension=none],
4099         [
4100         for cf_try_xopen_extension in _XOPEN_SOURCE_EXTENDED NCURSES_WIDECHAR
4101         do
4102                 AC_TRY_LINK([
4103 #define $cf_try_xopen_extension 1
4104 #include <stdlib.h>
4105 #include <${cf_cv_ncurses_header:-curses.h}>],[
4106 #ifdef NCURSES_VERSION
4107                 cchar_t check;
4108                 int check2 = curs_set((int)sizeof(check));
4109 #endif
4110                 long x = winnstr(stdscr, "", 0);
4111                 int x1, y1;
4112                 getbegyx(stdscr, y1, x1);
4113 #ifdef NCURSES_VERSION
4114                 (void)check2;
4115 #endif
4116                 (void)x;
4117                 (void)y1;
4118                 (void)x1;
4119                 ],
4120                 [cf_cv_need_xopen_extension=$cf_try_xopen_extension; break])
4121         done
4122         ])
4123 ])
4124
4125 case $cf_cv_need_xopen_extension in
4126 (*_*)
4127         CF_APPEND_TEXT(CPPFLAGS,-D$cf_cv_need_xopen_extension)
4128         ;;
4129 esac
4130
4131 ])dnl
4132 dnl ---------------------------------------------------------------------------
4133 dnl CF_XOPEN_SOURCE version: 55 updated: 2018/12/31 20:46:17
4134 dnl ---------------
4135 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
4136 dnl or adapt to the vendor's definitions to get equivalent functionality,
4137 dnl without losing the common non-POSIX features.
4138 dnl
4139 dnl Parameters:
4140 dnl     $1 is the nominal value for _XOPEN_SOURCE
4141 dnl     $2 is the nominal value for _POSIX_C_SOURCE
4142 AC_DEFUN([CF_XOPEN_SOURCE],[
4143 AC_REQUIRE([AC_CANONICAL_HOST])
4144 AC_REQUIRE([CF_POSIX_VISIBLE])
4145
4146 if test "$cf_cv_posix_visible" = no; then
4147
4148 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
4149 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
4150 cf_xopen_source=
4151
4152 case $host_os in
4153 (aix[[4-7]]*)
4154         cf_xopen_source="-D_ALL_SOURCE"
4155         ;;
4156 (msys)
4157         cf_XOPEN_SOURCE=600
4158         ;;
4159 (darwin[[0-8]].*)
4160         cf_xopen_source="-D_APPLE_C_SOURCE"
4161         ;;
4162 (darwin*)
4163         cf_xopen_source="-D_DARWIN_C_SOURCE"
4164         cf_XOPEN_SOURCE=
4165         ;;
4166 (freebsd*|dragonfly*|midnightbsd*)
4167         # 5.x headers associate
4168         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
4169         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
4170         cf_POSIX_C_SOURCE=200112L
4171         cf_XOPEN_SOURCE=600
4172         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
4173         ;;
4174 (hpux11*)
4175         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
4176         ;;
4177 (hpux*)
4178         cf_xopen_source="-D_HPUX_SOURCE"
4179         ;;
4180 (irix[[56]].*)
4181         cf_xopen_source="-D_SGI_SOURCE"
4182         cf_XOPEN_SOURCE=
4183         ;;
4184 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
4185         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
4186         ;;
4187 (minix*)
4188         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
4189         ;;
4190 (mirbsd*)
4191         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
4192         cf_XOPEN_SOURCE=
4193         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
4194         ;;
4195 (netbsd*)
4196         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
4197         ;;
4198 (openbsd[[4-9]]*)
4199         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
4200         cf_xopen_source="-D_BSD_SOURCE"
4201         cf_XOPEN_SOURCE=600
4202         ;;
4203 (openbsd*)
4204         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
4205         ;;
4206 (osf[[45]]*)
4207         cf_xopen_source="-D_OSF_SOURCE"
4208         ;;
4209 (nto-qnx*)
4210         cf_xopen_source="-D_QNX_SOURCE"
4211         ;;
4212 (sco*)
4213         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
4214         ;;
4215 (solaris2.*)
4216         cf_xopen_source="-D__EXTENSIONS__"
4217         cf_cv_xopen_source=broken
4218         ;;
4219 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
4220         cf_XOPEN_SOURCE=
4221         cf_POSIX_C_SOURCE=
4222         ;;
4223 (*)
4224         CF_TRY_XOPEN_SOURCE
4225         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
4226         ;;
4227 esac
4228
4229 if test -n "$cf_xopen_source" ; then
4230         CF_ADD_CFLAGS($cf_xopen_source,true)
4231 fi
4232
4233 dnl In anything but the default case, we may have system-specific setting
4234 dnl which is still not guaranteed to provide all of the entrypoints that
4235 dnl _XOPEN_SOURCE would yield.
4236 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
4237         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
4238         AC_TRY_COMPILE([#include <stdlib.h>],[
4239 #ifndef _XOPEN_SOURCE
4240 make an error
4241 #endif],
4242         [cf_XOPEN_SOURCE_set=yes],
4243         [cf_XOPEN_SOURCE_set=no])
4244         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
4245         if test $cf_XOPEN_SOURCE_set = yes
4246         then
4247                 AC_TRY_COMPILE([#include <stdlib.h>],[
4248 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
4249 make an error
4250 #endif],
4251                 [cf_XOPEN_SOURCE_set_ok=yes],
4252                 [cf_XOPEN_SOURCE_set_ok=no])
4253                 if test $cf_XOPEN_SOURCE_set_ok = no
4254                 then
4255                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
4256                 fi
4257         else
4258                 CF_TRY_XOPEN_SOURCE
4259         fi
4260 fi
4261 fi # cf_cv_posix_visible
4262 ])
4263 dnl ---------------------------------------------------------------------------
4264 dnl CF_X_ATHENA version: 24 updated: 2020/03/10 18:53:47
4265 dnl -----------
4266 dnl Check for Xaw (Athena) libraries
4267 dnl
4268 dnl Sets $cf_x_athena according to the flavor of Xaw which is used.
4269 AC_DEFUN([CF_X_ATHENA],
4270 [
4271 cf_x_athena=${cf_x_athena:-Xaw}
4272
4273 AC_MSG_CHECKING(if you want to link with Xaw 3d library)
4274 withval=
4275 AC_ARG_WITH(Xaw3d,
4276         [  --with-Xaw3d            link with Xaw 3d library])
4277 if test "$withval" = yes ; then
4278         cf_x_athena=Xaw3d
4279         AC_MSG_RESULT(yes)
4280 else
4281         AC_MSG_RESULT(no)
4282 fi
4283
4284 AC_MSG_CHECKING(if you want to link with Xaw 3d xft library)
4285 withval=
4286 AC_ARG_WITH(Xaw3dxft,
4287         [  --with-Xaw3dxft         link with Xaw 3d xft library])
4288 if test "$withval" = yes ; then
4289         cf_x_athena=Xaw3dxft
4290         AC_MSG_RESULT(yes)
4291 else
4292         AC_MSG_RESULT(no)
4293 fi
4294
4295 AC_MSG_CHECKING(if you want to link with neXT Athena library)
4296 withval=
4297 AC_ARG_WITH(neXtaw,
4298         [  --with-neXtaw           link with neXT Athena library])
4299 if test "$withval" = yes ; then
4300         cf_x_athena=neXtaw
4301         AC_MSG_RESULT(yes)
4302 else
4303         AC_MSG_RESULT(no)
4304 fi
4305
4306 AC_MSG_CHECKING(if you want to link with Athena-Plus library)
4307 withval=
4308 AC_ARG_WITH(XawPlus,
4309         [  --with-XawPlus          link with Athena-Plus library])
4310 if test "$withval" = yes ; then
4311         cf_x_athena=XawPlus
4312         AC_MSG_RESULT(yes)
4313 else
4314         AC_MSG_RESULT(no)
4315 fi
4316
4317 cf_x_athena_lib=""
4318
4319 if test "$PKG_CONFIG" != none ; then
4320         cf_athena_list=
4321         test "$cf_x_athena" = Xaw && cf_athena_list="xaw8 xaw7 xaw6"
4322         for cf_athena_pkg in \
4323                 $cf_athena_list \
4324                 ${cf_x_athena} \
4325                 ${cf_x_athena}-devel \
4326                 lib${cf_x_athena} \
4327                 lib${cf_x_athena}-devel
4328         do
4329                 CF_TRY_PKG_CONFIG($cf_athena_pkg,[
4330                         cf_x_athena_lib="$cf_pkgconfig_libs"
4331                         CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
4332                         AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
4333
4334                         CF_TRIM_X_LIBS
4335
4336 AC_CACHE_CHECK(for usable $cf_x_athena/Xmu package,cf_cv_xaw_compat,[
4337 AC_TRY_LINK([
4338 #include <X11/Xmu/CharSet.h>
4339 ],[
4340 int check = XmuCompareISOLatin1("big", "small");
4341 (void)check;
4342 ],[cf_cv_xaw_compat=yes],[cf_cv_xaw_compat=no])])
4343
4344                         if test "$cf_cv_xaw_compat" = no
4345                         then
4346                                 # workaround for broken ".pc" files...
4347                                 case "$cf_x_athena_lib" in
4348                                 (*-lXmu*)
4349                                         ;;
4350                                 (*)
4351                                         CF_VERBOSE(work around broken package)
4352                                         cf_save_xmu="$LIBS"
4353                                         cf_first_lib=`echo "$cf_save_xmu" | sed -e 's/^[ ][ ]*//' -e 's/ .*//'`
4354                                         CF_TRY_PKG_CONFIG(xmu,[
4355                                                         LIBS="$cf_save_xmu"
4356                                                         CF_ADD_LIB_AFTER($cf_first_lib,$cf_pkgconfig_libs)
4357                                                 ],[
4358                                                         CF_ADD_LIB_AFTER($cf_first_lib,-lXmu)
4359                                                 ])
4360                                         CF_TRIM_X_LIBS
4361                                         ;;
4362                                 esac
4363                         fi
4364
4365                         break])
4366         done
4367 fi
4368
4369 if test -z "$cf_x_athena_lib" ; then
4370         CF_X_EXT
4371         CF_X_TOOLKIT
4372         CF_X_ATHENA_CPPFLAGS($cf_x_athena)
4373         CF_X_ATHENA_LIBS($cf_x_athena)
4374 fi
4375 ])dnl
4376 dnl ---------------------------------------------------------------------------
4377 dnl CF_X_ATHENA_CPPFLAGS version: 8 updated: 2020/01/16 05:21:56
4378 dnl --------------------
4379 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
4380 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
4381 AC_DEFUN([CF_X_ATHENA_CPPFLAGS],
4382 [
4383 AC_REQUIRE([AC_PATH_XTRA])
4384 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
4385 cf_x_athena_inc=""
4386
4387 for cf_path in default \
4388         /usr/contrib/X11R6 \
4389         /usr/contrib/X11R5 \
4390         /usr/lib/X11R5 \
4391         /usr/local
4392 do
4393         if test -z "$cf_x_athena_inc" ; then
4394                 CF_SAVE_XTRA_FLAGS([CF_X_ATHENA_CPPFLAGS])
4395                 cf_test=X11/$cf_x_athena_root/SimpleMenu.h
4396                 if test $cf_path != default ; then
4397                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_path/include)
4398                         AC_MSG_CHECKING(for $cf_test in $cf_path)
4399                 else
4400                         AC_MSG_CHECKING(for $cf_test)
4401                 fi
4402                 AC_TRY_COMPILE([
4403 #include <X11/Intrinsic.h>
4404 #include <$cf_test>],[],
4405                         [cf_result=yes],
4406                         [cf_result=no])
4407                 AC_MSG_RESULT($cf_result)
4408                 CF_RESTORE_XTRA_FLAGS([CF_X_ATHENA_CPPFLAGS])
4409                 if test "$cf_result" = yes ; then
4410                         test "$cf_path"  = default && cf_x_athena_inc=default
4411                         test "$cf_path" != default && cf_x_athena_inc=$cf_path/include
4412                         break
4413                 fi
4414         fi
4415 done
4416
4417 if test -z "$cf_x_athena_inc" ; then
4418         AC_MSG_WARN([Unable to find Athena header files])
4419 elif test "$cf_x_athena_inc" != default ; then
4420         CF_APPEND_TEXT(CPPFLAGS,-I$cf_x_athena_inc)
4421 fi
4422 ])
4423 dnl ---------------------------------------------------------------------------
4424 dnl CF_X_ATHENA_LIBS version: 13 updated: 2020/01/11 18:16:10
4425 dnl ----------------
4426 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
4427 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
4428 AC_DEFUN([CF_X_ATHENA_LIBS],
4429 [AC_REQUIRE([CF_X_TOOLKIT])
4430 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
4431 cf_x_athena_lib=""
4432
4433 for cf_path in default \
4434         /usr/contrib/X11R6 \
4435         /usr/contrib/X11R5 \
4436         /usr/lib/X11R5 \
4437         /usr/local
4438 do
4439         for cf_lib in \
4440                 ${cf_x_athena_root} \
4441                 ${cf_x_athena_root}7 \
4442                 ${cf_x_athena_root}6
4443         do
4444         for cf_libs in \
4445                 "-l$cf_lib -lXmu" \
4446                 "-l$cf_lib -lXpm -lXmu" \
4447                 "-l${cf_lib}_s -lXmu_s"
4448         do
4449                 test -n "$cf_x_athena_lib" && break
4450
4451                 CF_SAVE_XTRA_FLAGS([CF_X_ATHENA_LIBS])
4452                 cf_test=XawSimpleMenuAddGlobalActions
4453                 test "$cf_path" != default && cf_libs="-L$cf_path/lib $cf_libs"
4454                 CF_ADD_LIBS($cf_libs)
4455                 AC_MSG_CHECKING(for $cf_test in $cf_libs)
4456                 AC_TRY_LINK([
4457 #include <X11/Intrinsic.h>
4458 #include <X11/$cf_x_athena_root/SimpleMenu.h>
4459 ],[
4460 $cf_test((XtAppContext) 0)],
4461                         [cf_result=yes],
4462                         [cf_result=no])
4463                 AC_MSG_RESULT($cf_result)
4464                 CF_RESTORE_XTRA_FLAGS([CF_X_ATHENA_LIBS])
4465
4466                 if test "$cf_result" = yes ; then
4467                         cf_x_athena_lib="$cf_libs"
4468                         break
4469                 fi
4470         done # cf_libs
4471                 test -n "$cf_x_athena_lib" && break
4472         done # cf_lib
4473 done
4474
4475 if test -z "$cf_x_athena_lib" ; then
4476         AC_MSG_ERROR(
4477 [Unable to successfully link Athena library (-l$cf_x_athena_root) with test program])
4478 fi
4479
4480 CF_ADD_LIBS($cf_x_athena_lib)
4481 CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
4482 AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
4483 ])
4484 dnl ---------------------------------------------------------------------------
4485 dnl CF_X_EXT version: 3 updated: 2010/06/02 05:03:05
4486 dnl --------
4487 AC_DEFUN([CF_X_EXT],[
4488 CF_TRY_PKG_CONFIG(Xext,,[
4489         AC_CHECK_LIB(Xext,XextCreateExtension,
4490                 [CF_ADD_LIB(Xext)])])
4491 ])dnl
4492 dnl ---------------------------------------------------------------------------
4493 dnl CF_X_TOOLKIT version: 25 updated: 2020/03/10 17:26:15
4494 dnl ------------
4495 dnl Check for X Toolkit libraries
4496 AC_DEFUN([CF_X_TOOLKIT],
4497 [
4498 AC_REQUIRE([AC_PATH_XTRA])
4499 AC_REQUIRE([CF_CHECK_CACHE])
4500
4501 # OSX is schizoid about who owns /usr/X11 (old) versus /opt/X11 (new) (and
4502 # in some cases has installed dummy files in the former, other cases replaced
4503 # it with a link to the new location).  This complicates the configure script.
4504 # Check for that pitfall, and recover using pkg-config
4505 #
4506 # If none of these are set, the configuration is almost certainly broken.
4507 if test -z "${X_CFLAGS}${X_PRE_LIBS}${X_LIBS}${X_EXTRA_LIBS}"
4508 then
4509         CF_TRY_PKG_CONFIG(x11,,[AC_MSG_WARN(unable to find X11 library)])
4510         CF_TRY_PKG_CONFIG(ice,,[AC_MSG_WARN(unable to find ICE library)])
4511         CF_TRY_PKG_CONFIG(sm,,[AC_MSG_WARN(unable to find SM library)])
4512         CF_TRY_PKG_CONFIG(xt,,[AC_MSG_WARN(unable to find Xt library)])
4513 else
4514         LIBS="$X_PRE_LIBS $LIBS $X_EXTRA_LIBS"
4515 fi
4516
4517 cf_have_X_LIBS=no
4518
4519 CF_TRY_PKG_CONFIG(xt,[
4520
4521         case "x$LIBS" in
4522         (*-lX11*)
4523                 ;;
4524         (*)
4525 # we have an "xt" package, but it may omit Xt's dependency on X11
4526 AC_CACHE_CHECK(for usable X dependency,cf_cv_xt_x11_compat,[
4527 AC_TRY_LINK([
4528 #include <X11/Xlib.h>
4529 ],[
4530         int rc1 = XDrawLine((Display*) 0, (Drawable) 0, (GC) 0, 0, 0, 0, 0);
4531         int rc2 = XClearWindow((Display*) 0, (Window) 0);
4532         int rc3 = XMoveWindow((Display*) 0, (Window) 0, 0, 0);
4533         int rc4 = XMoveResizeWindow((Display*)0, (Window)0, 0, 0, 0, 0);
4534 ],[cf_cv_xt_x11_compat=yes],[cf_cv_xt_x11_compat=no])])
4535                 if test "$cf_cv_xt_x11_compat" = no
4536                 then
4537                         CF_VERBOSE(work around broken X11 dependency)
4538                         # 2010/11/19 - good enough until a working Xt on Xcb is delivered.
4539                         CF_TRY_PKG_CONFIG(x11,,[CF_ADD_LIB_AFTER(-lXt,-lX11)])
4540                 fi
4541                 ;;
4542         esac
4543
4544 AC_CACHE_CHECK(for usable X Toolkit package,cf_cv_xt_ice_compat,[
4545 AC_TRY_LINK([
4546 #include <X11/Shell.h>
4547 ],[int num = IceConnectionNumber(0); (void) num
4548 ],[cf_cv_xt_ice_compat=yes],[cf_cv_xt_ice_compat=no])])
4549
4550         if test "$cf_cv_xt_ice_compat" = no
4551         then
4552                 # workaround for broken ".pc" files used for X Toolkit.
4553                 case "x$X_PRE_LIBS" in
4554                 (*-lICE*)
4555                         case "x$LIBS" in
4556                         (*-lICE*)
4557                                 ;;
4558                         (*)
4559                                 CF_VERBOSE(work around broken ICE dependency)
4560                                 CF_TRY_PKG_CONFIG(ice,
4561                                         [CF_TRY_PKG_CONFIG(sm)],
4562                                         [CF_ADD_LIB_AFTER(-lXt,$X_PRE_LIBS)])
4563                                 ;;
4564                         esac
4565                         ;;
4566                 esac
4567         fi
4568
4569         cf_have_X_LIBS=yes
4570 ],[
4571
4572         LDFLAGS="$X_LIBS $LDFLAGS"
4573         CF_CHECK_CFLAGS($X_CFLAGS)
4574
4575         AC_CHECK_FUNC(XOpenDisplay,,[
4576         AC_CHECK_LIB(X11,XOpenDisplay,
4577                 [CF_ADD_LIB(X11)])])
4578
4579         AC_CHECK_FUNC(XtAppInitialize,,[
4580         AC_CHECK_LIB(Xt, XtAppInitialize,
4581                 [AC_DEFINE(HAVE_LIBXT,1,[Define to 1 if we can compile with the Xt library])
4582                  cf_have_X_LIBS=Xt
4583                  LIBS="-lXt $LIBS"])])
4584 ])
4585
4586 if test $cf_have_X_LIBS = no ; then
4587         AC_MSG_WARN(
4588 [Unable to successfully link X Toolkit library (-lXt) with
4589 test program.  You will have to check and add the proper libraries by hand
4590 to makefile.])
4591 fi
4592 ])dnl
4593 dnl ---------------------------------------------------------------------------
4594 dnl CF__CURSES_DATA version: 2 updated: 2020/02/08 21:00:26
4595 dnl ---------------
4596 dnl Attempt to make a copy of a curses data item.  This is needed in the
4597 dnl check-data configure tests when using ncurses, because the symbol may be
4598 dnl actually a function return-value.  That could happen if the linker is
4599 dnl broken (does not resolve data-only references), or if ncurses is configured
4600 dnl to support re-entrant code.
4601 dnl $1 = target
4602 dnl $2 = source
4603 define([CF__CURSES_DATA],[
4604 #if defined($2) && ((defined(NCURSES_WRAPPED_VAR) && (NCURSES_VERSION_PATCH < 20200208)) || defined(NCURSES_BROKEN_LINKER) || defined(NCURSES_REENTRANT))
4605         const void *$1 = (const void *)($2);
4606 #else
4607         const void *$1 = &($2);
4608 #endif
4609         fprintf(stderr, "testing linkage of $2:%p\n", (const void *)$1);
4610 ])dnl
4611 dnl ---------------------------------------------------------------------------
4612 dnl CF__CURSES_HEAD version: 2 updated: 2010/10/23 15:54:49
4613 dnl ---------------
4614 dnl Define a reusable chunk which includes <curses.h> and <term.h> when they
4615 dnl are both available.
4616 define([CF__CURSES_HEAD],[
4617 #ifdef HAVE_XCURSES
4618 #include <xcurses.h>
4619 char * XCursesProgramName = "test";
4620 #else
4621 #include <${cf_cv_ncurses_header:-curses.h}>
4622 #if defined(NCURSES_VERSION) && defined(HAVE_NCURSESW_TERM_H)
4623 #include <ncursesw/term.h>
4624 #elif defined(NCURSES_VERSION) && defined(HAVE_NCURSES_TERM_H)
4625 #include <ncurses/term.h>
4626 #elif defined(HAVE_TERM_H)
4627 #include <term.h>
4628 #endif
4629 #endif
4630 ])