a2458869f2a6e8c0202926a6cb3615a94e03bc10
[ncurses.git] / test / aclocal.m4
1 dnl***************************************************************************
2 dnl Copyright (c) 2003-2010,2011 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl $Id: aclocal.m4,v 1.62 2011/05/14 20:46:00 tom Exp $
30 dnl
31 dnl Author: Thomas E. Dickey
32 dnl
33 dnl Macros used in NCURSES test programs auto-configuration script.
34 dnl
35 dnl These macros are maintained separately from NCURSES.  The copyright on
36 dnl this file applies to the aggregation of macros and does not affect use of
37 dnl these macros in other applications.
38 dnl
39 dnl See http://invisible-island.net/autoconf/ for additional information.
40 dnl
41 dnl ---------------------------------------------------------------------------
42 dnl ---------------------------------------------------------------------------
43 dnl CF_ACVERSION_CHECK version: 2 updated: 2011/05/08 11:22:03
44 dnl ------------------
45 dnl Conditionally generate script according to whether we're using a given autoconf.
46 dnl
47 dnl $1 = version to compare against
48 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
49 dnl $3 = code to use if AC_ACVERSION is older than $1.
50 define(CF_ACVERSION_CHECK,
51 [
52 ifdef([m4_version_compare],
53 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
54 [CF_ACVERSION_COMPARE(
55 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
56 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
57 dnl ---------------------------------------------------------------------------
58 dnl CF_ACVERSION_COMPARE version: 2 updated: 2011/04/14 20:56:50
59 dnl --------------------
60 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
61 dnl                      MAJOR2, MINOR2, TERNARY2,
62 dnl                      PRINTABLE2, not FOUND, FOUND)
63 define(CF_ACVERSION_COMPARE,
64 [ifelse(builtin([eval], [$2 < $5]), 1,
65 [ifelse([$8], , ,[$8])],
66 [ifelse([$9], , ,[$9])])])dnl
67 dnl ---------------------------------------------------------------------------
68 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
69 dnl -------------
70 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
71 dnl The second parameter if given makes this macro verbose.
72 dnl
73 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
74 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
75 dnl confused by the quotes (which require backslashes to keep them usable).
76 AC_DEFUN([CF_ADD_CFLAGS],
77 [
78 cf_fix_cppflags=no
79 cf_new_cflags=
80 cf_new_cppflags=
81 cf_new_extra_cppflags=
82
83 for cf_add_cflags in $1
84 do
85 case $cf_fix_cppflags in
86 no)
87         case $cf_add_cflags in #(vi
88         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
89                 case $cf_add_cflags in
90                 -D*)
91                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
92
93                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
94                                 && test -z "${cf_tst_cflags}" \
95                                 && cf_fix_cppflags=yes
96
97                         if test $cf_fix_cppflags = yes ; then
98                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
99                                 continue
100                         elif test "${cf_tst_cflags}" = "\"'" ; then
101                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
102                                 continue
103                         fi
104                         ;;
105                 esac
106                 case "$CPPFLAGS" in
107                 *$cf_add_cflags) #(vi
108                         ;;
109                 *) #(vi
110                         case $cf_add_cflags in #(vi
111                         -D*)
112                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
113                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
114                                 ;;
115                         esac
116                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
117                         ;;
118                 esac
119                 ;;
120         *)
121                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
122                 ;;
123         esac
124         ;;
125 yes)
126         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
127
128         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
129
130         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
131                 && test -z "${cf_tst_cflags}" \
132                 && cf_fix_cppflags=no
133         ;;
134 esac
135 done
136
137 if test -n "$cf_new_cflags" ; then
138         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
139         CFLAGS="$CFLAGS $cf_new_cflags"
140 fi
141
142 if test -n "$cf_new_cppflags" ; then
143         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
144         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
145 fi
146
147 if test -n "$cf_new_extra_cppflags" ; then
148         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
149         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
150 fi
151
152 AC_SUBST(EXTRA_CPPFLAGS)
153
154 ])dnl
155 dnl ---------------------------------------------------------------------------
156 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
157 dnl -------------
158 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
159 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
160 dnl but old versions (and some misinstalled ones) need that.  To make things
161 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
162 dnl the include-path).
163 AC_DEFUN([CF_ADD_INCDIR],
164 [
165 if test -n "$1" ; then
166   for cf_add_incdir in $1
167   do
168         while test $cf_add_incdir != /usr/include
169         do
170           if test -d $cf_add_incdir
171           then
172                 cf_have_incdir=no
173                 if test -n "$CFLAGS$CPPFLAGS" ; then
174                   # a loop is needed to ensure we can add subdirs of existing dirs
175                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
176                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
177                           cf_have_incdir=yes; break
178                         fi
179                   done
180                 fi
181
182                 if test "$cf_have_incdir" = no ; then
183                   if test "$cf_add_incdir" = /usr/local/include ; then
184                         if test "$GCC" = yes
185                         then
186                           cf_save_CPPFLAGS=$CPPFLAGS
187                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
188                           AC_TRY_COMPILE([#include <stdio.h>],
189                                   [printf("Hello")],
190                                   [],
191                                   [cf_have_incdir=yes])
192                           CPPFLAGS=$cf_save_CPPFLAGS
193                         fi
194                   fi
195                 fi
196
197                 if test "$cf_have_incdir" = no ; then
198                   CF_VERBOSE(adding $cf_add_incdir to include-path)
199                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
200
201                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
202                   test "$cf_top_incdir" = "$cf_add_incdir" && break
203                   cf_add_incdir="$cf_top_incdir"
204                 else
205                   break
206                 fi
207           fi
208         done
209   done
210 fi
211 ])dnl
212 dnl ---------------------------------------------------------------------------
213 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
214 dnl ----------
215 dnl Add a library, used to enforce consistency.
216 dnl
217 dnl $1 = library to add, without the "-l"
218 dnl $2 = variable to update (default $LIBS)
219 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
220 dnl ---------------------------------------------------------------------------
221 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
222 dnl -------------
223 dnl     Adds to the library-path
224 dnl
225 dnl     Some machines have trouble with multiple -L options.
226 dnl
227 dnl $1 is the (list of) directory(s) to add
228 dnl $2 is the optional name of the variable to update (default LDFLAGS)
229 dnl
230 AC_DEFUN([CF_ADD_LIBDIR],
231 [
232 if test -n "$1" ; then
233   for cf_add_libdir in $1
234   do
235     if test $cf_add_libdir = /usr/lib ; then
236       :
237     elif test -d $cf_add_libdir
238     then
239       cf_have_libdir=no
240       if test -n "$LDFLAGS$LIBS" ; then
241         # a loop is needed to ensure we can add subdirs of existing dirs
242         for cf_test_libdir in $LDFLAGS $LIBS ; do
243           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
244             cf_have_libdir=yes; break
245           fi
246         done
247       fi
248       if test "$cf_have_libdir" = no ; then
249         CF_VERBOSE(adding $cf_add_libdir to library-path)
250         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
251       fi
252     fi
253   done
254 fi
255 ])dnl
256 dnl ---------------------------------------------------------------------------
257 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
258 dnl -----------
259 dnl Add one or more libraries, used to enforce consistency.
260 dnl
261 dnl $1 = libraries to add, with the "-l", etc.
262 dnl $2 = variable to update (default $LIBS)
263 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
264 dnl ---------------------------------------------------------------------------
265 dnl CF_ADD_LIB_AFTER version: 2 updated: 2010/11/08 20:33:46
266 dnl ----------------
267 dnl Add a given library after another, e.g., following the one it satisfies a
268 dnl dependency for.
269 dnl
270 dnl $1 = the first library
271 dnl $2 = its dependency
272 AC_DEFUN([CF_ADD_LIB_AFTER],[
273 CF_VERBOSE(...before $LIBS)
274 LIBS=`echo "$LIBS" | sed -e "s/[[       ]][[    ]]*/ /g" -e "s,$1 ,$1 $2 ," -e 's/  / /g'`
275 CF_VERBOSE(...after  $LIBS)
276 ])dnl
277 dnl ---------------------------------------------------------------------------
278 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
279 dnl ------------------
280 dnl Append to a search-list for a nonstandard header/lib-file
281 dnl     $1 = the variable to return as result
282 dnl     $2 = the package name
283 dnl     $3 = the subdirectory, e.g., bin, include or lib
284 dnl $4 = the directory under which we will test for subdirectories
285 dnl $5 = a directory that we do not want $4 to match
286 AC_DEFUN([CF_ADD_SUBDIR_PATH],
287 [
288 test "$4" != "$5" && \
289 test -d "$4" && \
290 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
291         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
292         test -d $4/$3 &&          $1="[$]$1 $4/$3"
293         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
294         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
295         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
296         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
297 }
298 ])dnl
299 dnl ---------------------------------------------------------------------------
300 dnl CF_ANSI_CC_CHECK version: 10 updated: 2010/10/23 15:52:32
301 dnl ----------------
302 dnl This is adapted from the macros 'fp_PROG_CC_STDC' and 'fp_C_PROTOTYPES'
303 dnl in the sharutils 4.2 distribution.
304 AC_DEFUN([CF_ANSI_CC_CHECK],
305 [
306 AC_CACHE_CHECK(for ${CC:-cc} option to accept ANSI C, cf_cv_ansi_cc,[
307 cf_cv_ansi_cc=no
308 cf_save_CFLAGS="$CFLAGS"
309 cf_save_CPPFLAGS="$CPPFLAGS"
310 # Don't try gcc -ansi; that turns off useful extensions and
311 # breaks some systems' header files.
312 # AIX                   -qlanglvl=ansi
313 # Ultrix and OSF/1      -std1
314 # HP-UX                 -Aa -D_HPUX_SOURCE
315 # SVR4                  -Xc
316 # UnixWare 1.2          (cannot use -Xc, since ANSI/POSIX clashes)
317 for cf_arg in "-DCC_HAS_PROTOS" \
318         "" \
319         -qlanglvl=ansi \
320         -std1 \
321         -Ae \
322         "-Aa -D_HPUX_SOURCE" \
323         -Xc
324 do
325         CF_ADD_CFLAGS($cf_arg)
326         AC_TRY_COMPILE(
327 [
328 #ifndef CC_HAS_PROTOS
329 #if !defined(__STDC__) || (__STDC__ != 1)
330 choke me
331 #endif
332 #endif
333 ],[
334         int test (int i, double x);
335         struct s1 {int (*f) (int a);};
336         struct s2 {int (*f) (double a);};],
337         [cf_cv_ansi_cc="$cf_arg"; break])
338 done
339 CFLAGS="$cf_save_CFLAGS"
340 CPPFLAGS="$cf_save_CPPFLAGS"
341 ])
342
343 if test "$cf_cv_ansi_cc" != "no"; then
344 if test ".$cf_cv_ansi_cc" != ".-DCC_HAS_PROTOS"; then
345         CF_ADD_CFLAGS($cf_cv_ansi_cc)
346 else
347         AC_DEFINE(CC_HAS_PROTOS)
348 fi
349 fi
350 ])dnl
351 dnl ---------------------------------------------------------------------------
352 dnl CF_ANSI_CC_REQD version: 4 updated: 2008/03/23 14:48:54
353 dnl ---------------
354 dnl For programs that must use an ANSI compiler, obtain compiler options that
355 dnl will make it recognize prototypes.  We'll do preprocessor checks in other
356 dnl macros, since tools such as unproto can fake prototypes, but only part of
357 dnl the preprocessor.
358 AC_DEFUN([CF_ANSI_CC_REQD],
359 [AC_REQUIRE([CF_ANSI_CC_CHECK])
360 if test "$cf_cv_ansi_cc" = "no"; then
361         AC_MSG_ERROR(
362 [Your compiler does not appear to recognize prototypes.
363 You have the following choices:
364         a. adjust your compiler options
365         b. get an up-to-date compiler
366         c. use a wrapper such as unproto])
367 fi
368 ])dnl
369 dnl ---------------------------------------------------------------------------
370 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
371 dnl --------------
372 dnl Allow user to disable a normally-on option.
373 AC_DEFUN([CF_ARG_DISABLE],
374 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
375 dnl ---------------------------------------------------------------------------
376 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
377 dnl -------------
378 dnl Allow user to enable a normally-off option.
379 AC_DEFUN([CF_ARG_ENABLE],
380 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
381 dnl ---------------------------------------------------------------------------
382 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
383 dnl -------------
384 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
385 dnl values.
386 dnl
387 dnl Parameters:
388 dnl $1 = option name
389 dnl $2 = help-string
390 dnl $3 = action to perform if option is not default
391 dnl $4 = action if perform if option is default
392 dnl $5 = default option value (either 'yes' or 'no')
393 AC_DEFUN([CF_ARG_OPTION],
394 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
395   if test "$enableval" != "$5" ; then
396 ifelse([$3],,[    :]dnl
397 ,[    $3]) ifelse([$4],,,[
398   else
399     $4])
400   fi],[enableval=$5 ifelse([$4],,,[
401   $4
402 ])dnl
403   ])])dnl
404 dnl ---------------------------------------------------------------------------
405 dnl CF_CHECK_CACHE version: 11 updated: 2008/03/23 14:45:59
406 dnl --------------
407 dnl Check if we're accidentally using a cache from a different machine.
408 dnl Derive the system name, as a check for reusing the autoconf cache.
409 dnl
410 dnl If we've packaged config.guess and config.sub, run that (since it does a
411 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
412 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
413 dnl which is useful in cross-compiles.
414 dnl
415 dnl Note: we would use $ac_config_sub, but that is one of the places where
416 dnl autoconf 2.5x broke compatibility with autoconf 2.13
417 AC_DEFUN([CF_CHECK_CACHE],
418 [
419 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
420         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
421         system_name="$host_os"
422 else
423         system_name="`(uname -s -r) 2>/dev/null`"
424         if test -z "$system_name" ; then
425                 system_name="`(hostname) 2>/dev/null`"
426         fi
427 fi
428 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name")
429 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
430
431 test -z "$system_name" && system_name="$cf_cv_system_name"
432 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
433
434 if test ".$system_name" != ".$cf_cv_system_name" ; then
435         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
436         AC_MSG_ERROR("Please remove config.cache and try again.")
437 fi
438 ])dnl
439 dnl ---------------------------------------------------------------------------
440 dnl CF_CHECK_CFLAGS version: 2 updated: 2001/12/30 19:09:58
441 dnl ---------------
442 dnl Conditionally add to $CFLAGS and $CPPFLAGS values which are derived from
443 dnl a build-configuration such as imake.  These have the pitfall that they
444 dnl often contain compiler-specific options which we cannot use, mixed with
445 dnl preprocessor options that we usually can.
446 AC_DEFUN([CF_CHECK_CFLAGS],
447 [
448 CF_VERBOSE(checking additions to CFLAGS)
449 cf_check_cflags="$CFLAGS"
450 cf_check_cppflags="$CPPFLAGS"
451 CF_ADD_CFLAGS($1,yes)
452 if test "$cf_check_cflags" != "$CFLAGS" ; then
453 AC_TRY_LINK([#include <stdio.h>],[printf("Hello world");],,
454         [CF_VERBOSE(test-compile failed.  Undoing change to \$CFLAGS)
455          if test "$cf_check_cppflags" != "$CPPFLAGS" ; then
456                  CF_VERBOSE(but keeping change to \$CPPFLAGS)
457          fi
458          CFLAGS="$cf_check_flags"])
459 fi
460 ])dnl
461 dnl ---------------------------------------------------------------------------
462 dnl CF_CURSES_ACS_MAP version: 6 updated: 2010/10/23 15:54:49
463 dnl -----------------
464 dnl Check for likely values of acs_map[]:
465 AC_DEFUN([CF_CURSES_ACS_MAP],
466 [
467 AC_REQUIRE([CF_NCURSES_WRAP_PREFIX])dnl
468 AC_CACHE_CHECK(for alternate character set array, cf_cv_curses_acs_map,[
469 cf_cv_curses_acs_map=unknown
470 for name in acs_map _acs_map __acs_map ${NCURSES_WRAP_PREFIX}acs_map
471 do
472 AC_TRY_LINK([
473 #include <${cf_cv_ncurses_header:-curses.h}>
474 ],[
475 $name['k'] = ACS_PLUS
476 ],[cf_cv_curses_acs_map=$name; break])
477 done
478 ])
479
480 test "$cf_cv_curses_acs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_ACS_ARRAY,$cf_cv_curses_acs_map)
481 ])
482 dnl ---------------------------------------------------------------------------
483 dnl CF_CURSES_CHECK_DATA version: 4 updated: 2011/01/15 16:39:24
484 dnl --------------------
485 dnl Check if curses.h defines the given data/variable.
486 dnl Use this after CF_NCURSES_CONFIG or CF_CURSES_CONFIG.
487 AC_DEFUN([CF_CURSES_CHECK_DATA],
488 [
489 AC_MSG_CHECKING(for data $1 declaration in ${cf_cv_ncurses_header:-curses.h})
490
491 AC_TRY_COMPILE(CF__CURSES_HEAD,[
492 void *foo = &($1)
493 ],cf_result=yes,cf_result=no)
494 AC_MSG_RESULT($cf_result)
495
496 if test $cf_result = yes ; then
497         CF_UPPER(cf_result,have_curses_data_$1)
498         AC_DEFINE_UNQUOTED($cf_result)
499 else
500         AC_MSG_CHECKING(for data $1 in library)
501         # BSD linkers insist on making weak linkage, but resolve at runtime.
502         AC_TRY_RUN(CF__CURSES_HEAD
503 [
504 extern char $1;
505 int main(void)
506 {
507         void *foo = &($1);
508         ${cf_cv_main_return:-return}(foo == 0);
509 }],[cf_result=yes],[cf_result=no],[
510         # cross-compiling
511         AC_TRY_LINK(CF__CURSES_HEAD
512 [extern char $1;],[
513         do {
514                 void *foo = &($1);
515                 ${cf_cv_main_return:-return}(foo == 0);
516         } while (0)
517 ],[cf_result=yes],[cf_result=no])
518 ])
519         AC_MSG_RESULT($cf_result)
520         if test $cf_result = yes ; then
521                 CF_UPPER(cf_result,decl_curses_data_$1)
522                 AC_DEFINE_UNQUOTED($cf_result)
523         fi
524 fi
525 ])dnl
526 dnl ---------------------------------------------------------------------------
527 dnl CF_CURSES_CHECK_TYPE version: 3 updated: 2010/10/23 15:54:49
528 dnl --------------------
529 dnl Check if curses.h defines the given type
530 AC_DEFUN([CF_CURSES_CHECK_TYPE],
531 [
532 AC_MSG_CHECKING(for type $1 in ${cf_cv_ncurses_header:-curses.h})
533 AC_TRY_COMPILE([
534 #ifndef _XOPEN_SOURCE_EXTENDED
535 #define _XOPEN_SOURCE_EXTENDED
536 #endif
537 #include <${cf_cv_ncurses_header:-curses.h}>],[
538 $1 foo
539 ],cf_result=yes,cf_result=no)
540 AC_MSG_RESULT($cf_result)
541 if test $cf_result = yes ; then
542         CF_UPPER(cf_result,have_type_$1)
543         AC_DEFINE_UNQUOTED($cf_result)
544 else
545         AC_DEFINE_UNQUOTED($1,$2)
546 fi
547 ])dnl
548 dnl ---------------------------------------------------------------------------
549 dnl CF_CURSES_CONFIG version: 2 updated: 2006/10/29 11:06:27
550 dnl ----------------
551 dnl Tie together the configure-script macros for curses.  It may be ncurses,
552 dnl but unless asked, we do not make a special search for ncurses.  However,
553 dnl still check for the ncurses version number, for use in other macros.
554 AC_DEFUN([CF_CURSES_CONFIG],
555 [
556 CF_CURSES_CPPFLAGS
557 CF_NCURSES_VERSION
558 CF_CURSES_LIBS
559 ])dnl
560 dnl ---------------------------------------------------------------------------
561 dnl CF_CURSES_CPPFLAGS version: 11 updated: 2011/04/09 14:51:08
562 dnl ------------------
563 dnl Look for the curses headers.
564 AC_DEFUN([CF_CURSES_CPPFLAGS],[
565
566 AC_CACHE_CHECK(for extra include directories,cf_cv_curses_incdir,[
567 cf_cv_curses_incdir=no
568 case $host_os in #(vi
569 hpux10.*) #(vi
570         if test "x$cf_cv_screen" = "xcurses_colr"
571         then
572                 test -d /usr/include/curses_colr && \
573                 cf_cv_curses_incdir="-I/usr/include/curses_colr"
574         fi
575         ;;
576 sunos3*|sunos4*)
577         if test "x$cf_cv_screen" = "xcurses_5lib"
578         then
579                 test -d /usr/5lib && \
580                 test -d /usr/5include && \
581                 cf_cv_curses_incdir="-I/usr/5include"
582         fi
583         ;;
584 esac
585 ])
586 test "$cf_cv_curses_incdir" != no && CPPFLAGS="$CPPFLAGS $cf_cv_curses_incdir"
587
588 CF_CURSES_HEADER
589 CF_TERM_HEADER
590 ])dnl
591 dnl ---------------------------------------------------------------------------
592 dnl CF_CURSES_FUNCS version: 17 updated: 2011/05/14 16:07:29
593 dnl ---------------
594 dnl Curses-functions are a little complicated, since a lot of them are macros.
595 AC_DEFUN([CF_CURSES_FUNCS],
596 [
597 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
598 AC_REQUIRE([CF_XOPEN_CURSES])
599 AC_REQUIRE([CF_CURSES_TERM_H])
600 AC_REQUIRE([CF_CURSES_UNCTRL_H])
601 for cf_func in $1
602 do
603         CF_UPPER(cf_tr_func,$cf_func)
604         AC_MSG_CHECKING(for ${cf_func})
605         CF_MSG_LOG(${cf_func})
606         AC_CACHE_VAL(cf_cv_func_$cf_func,[
607                 eval cf_result='$ac_cv_func_'$cf_func
608                 if test ".$cf_result" != ".no"; then
609                         AC_TRY_LINK(CF__CURSES_HEAD,
610                         [
611 #ifndef ${cf_func}
612 long foo = (long)(&${cf_func});
613 if (foo + 1234 > 5678)
614         ${cf_cv_main_return:-return}(foo);
615 #endif
616                         ],
617                         [cf_result=yes],
618                         [cf_result=no])
619                 fi
620                 eval 'cf_cv_func_'$cf_func'=$cf_result'
621         ])
622         # use the computed/retrieved cache-value:
623         eval 'cf_result=$cf_cv_func_'$cf_func
624         AC_MSG_RESULT($cf_result)
625         if test $cf_result != no; then
626                 AC_DEFINE_UNQUOTED(HAVE_${cf_tr_func})
627         fi
628 done
629 ])dnl
630 dnl ---------------------------------------------------------------------------
631 dnl CF_CURSES_HEADER version: 3 updated: 2011/05/01 19:47:45
632 dnl ----------------
633 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
634 dnl variations of ncurses' installs.
635 dnl
636 dnl $1 = ncurses when looking for ncurses, or is empty
637 AC_DEFUN([CF_CURSES_HEADER],[
638 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
639 cf_cv_ncurses_header=none
640 for cf_header in ifelse($1,,,[ \
641     $1/ncurses.h \
642         $1/curses.h]) \
643         ncurses.h \
644         curses.h ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
645 do
646 AC_TRY_COMPILE([#include <${cf_header}>],
647         [initscr(); tgoto("?", 0,0)],
648         [cf_cv_ncurses_header=$cf_header; break],[])
649 done
650 ])
651
652 if test "$cf_cv_ncurses_header" = none ; then
653         AC_MSG_ERROR(No curses header-files found)
654 fi
655
656 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
657 AC_CHECK_HEADERS($cf_cv_ncurses_header)
658 ])dnl
659 dnl ---------------------------------------------------------------------------
660 dnl CF_CURSES_LIBS version: 34 updated: 2011/04/09 14:51:08
661 dnl --------------
662 dnl Look for the curses libraries.  Older curses implementations may require
663 dnl termcap/termlib to be linked as well.  Call CF_CURSES_CPPFLAGS first.
664 AC_DEFUN([CF_CURSES_LIBS],[
665
666 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
667 AC_MSG_CHECKING(if we have identified curses libraries)
668 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
669     [initscr(); tgoto("?", 0,0)],
670     cf_result=yes,
671     cf_result=no)
672 AC_MSG_RESULT($cf_result)
673
674 if test "$cf_result" = no ; then
675 case $host_os in #(vi
676 freebsd*) #(vi
677     AC_CHECK_LIB(mytinfo,tgoto,[CF_ADD_LIBS(-lmytinfo)])
678     ;;
679 hpux10.*) #(vi
680         # Looking at HPUX 10.20, the Hcurses library is the oldest (1997), cur_colr
681         # next (1998), and xcurses "newer" (2000).  There is no header file for
682         # Hcurses; the subdirectory curses_colr has the headers (curses.h and
683         # term.h) for cur_colr
684         if test "x$cf_cv_screen" = "xcurses_colr"
685         then
686                 AC_CHECK_LIB(cur_colr,initscr,[
687                         CF_ADD_LIBS(-lcur_colr)
688                         ac_cv_func_initscr=yes
689                         ],[
690                 AC_CHECK_LIB(Hcurses,initscr,[
691                         # HP's header uses __HP_CURSES, but user claims _HP_CURSES.
692                         CF_ADD_LIBS(-lHcurses)
693                         CPPFLAGS="$CPPFLAGS -D__HP_CURSES -D_HP_CURSES"
694                         ac_cv_func_initscr=yes
695                         ])])
696         fi
697     ;;
698 linux*)
699         case `arch 2>/dev/null` in
700         x86_64)
701                 if test -d /lib64
702                 then
703                         CF_ADD_LIBDIR(/lib64)
704                 else
705                         CF_ADD_LIBDIR(/lib)
706                 fi
707                 ;;
708         *)
709                 CF_ADD_LIBDIR(/lib)
710                 ;;
711         esac
712     ;;
713 sunos3*|sunos4*)
714         if test "x$cf_cv_screen" = "xcurses_5lib"
715         then
716                 if test -d /usr/5lib ; then
717                         CF_ADD_LIBDIR(/usr/5lib)
718                         CF_ADD_LIBS(-lcurses -ltermcap)
719                 fi
720     fi
721     ac_cv_func_initscr=yes
722     ;;
723 esac
724
725 if test ".$ac_cv_func_initscr" != .yes ; then
726     cf_save_LIBS="$LIBS"
727     cf_term_lib=""
728     cf_curs_lib=""
729
730     if test ".${cf_cv_ncurses_version:-no}" != .no
731     then
732         cf_check_list="ncurses curses cursesX"
733     else
734         cf_check_list="cursesX curses ncurses"
735     fi
736
737     # Check for library containing tgoto.  Do this before curses library
738     # because it may be needed to link the test-case for initscr.
739     AC_CHECK_FUNC(tgoto,[cf_term_lib=predefined],[
740         for cf_term_lib in $cf_check_list termcap termlib unknown
741         do
742             AC_CHECK_LIB($cf_term_lib,tgoto,[break])
743         done
744     ])
745
746     # Check for library containing initscr
747     test "$cf_term_lib" != predefined && test "$cf_term_lib" != unknown && LIBS="-l$cf_term_lib $cf_save_LIBS"
748         for cf_curs_lib in $cf_check_list xcurses jcurses pdcurses unknown
749     do
750         AC_CHECK_LIB($cf_curs_lib,initscr,[break])
751     done
752     test $cf_curs_lib = unknown && AC_MSG_ERROR(no curses library found)
753
754     LIBS="-l$cf_curs_lib $cf_save_LIBS"
755     if test "$cf_term_lib" = unknown ; then
756         AC_MSG_CHECKING(if we can link with $cf_curs_lib library)
757         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
758             [initscr()],
759             [cf_result=yes],
760             [cf_result=no])
761         AC_MSG_RESULT($cf_result)
762         test $cf_result = no && AC_MSG_ERROR(Cannot link curses library)
763     elif test "$cf_curs_lib" = "$cf_term_lib" ; then
764         :
765     elif test "$cf_term_lib" != predefined ; then
766         AC_MSG_CHECKING(if we need both $cf_curs_lib and $cf_term_lib libraries)
767         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
768             [initscr(); tgoto((char *)0, 0, 0);],
769             [cf_result=no],
770             [
771             LIBS="-l$cf_curs_lib -l$cf_term_lib $cf_save_LIBS"
772             AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
773                 [initscr()],
774                 [cf_result=yes],
775                 [cf_result=error])
776             ])
777         AC_MSG_RESULT($cf_result)
778     fi
779 fi
780 fi
781
782 ])dnl
783 dnl ---------------------------------------------------------------------------
784 dnl CF_CURSES_TERM_H version: 9 updated: 2011/04/09 18:19:55
785 dnl ----------------
786 dnl SVr4 curses should have term.h as well (where it puts the definitions of
787 dnl the low-level interface).  This may not be true in old/broken implementations,
788 dnl as well as in misconfigured systems (e.g., gcc configured for Solaris 2.4
789 dnl running with Solaris 2.5.1).
790 AC_DEFUN([CF_CURSES_TERM_H],
791 [
792 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
793
794 AC_CACHE_CHECK(for term.h, cf_cv_term_header,[
795
796 # If we found <ncurses/curses.h>, look for <ncurses/term.h>, but always look
797 # for <term.h> if we do not find the variant.
798
799 cf_header_list="term.h ncurses/term.h ncursesw/term.h"
800
801 case ${cf_cv_ncurses_header:-curses.h} in #(vi
802 */*)
803         cf_header_item=`echo ${cf_cv_ncurses_header:-curses.h} | sed -e 's%\..*%%' -e 's%/.*%/%'`term.h
804         cf_header_list="$cf_header_item $cf_header_list"
805         ;;
806 esac
807
808 for cf_header in $cf_header_list
809 do
810         AC_TRY_COMPILE([
811 #include <${cf_cv_ncurses_header:-curses.h}>
812 #include <${cf_header}>],
813         [WINDOW *x],
814         [cf_cv_term_header=$cf_header
815          break],
816         [cf_cv_term_header=no])
817 done
818
819 case $cf_cv_term_header in #(vi
820 no)
821         # If curses is ncurses, some packagers still mess it up by trying to make
822         # us use GNU termcap.  This handles the most common case.
823         for cf_header in ncurses/term.h ncursesw/term.h
824         do
825                 AC_TRY_COMPILE([
826 #include <${cf_cv_ncurses_header:-curses.h}>
827 #ifdef NCURSES_VERSION
828 #include <${cf_header}>
829 #else
830 make an error
831 #endif],
832                         [WINDOW *x],
833                         [cf_cv_term_header=$cf_header
834                          break],
835                         [cf_cv_term_header=no])
836         done
837         ;;
838 esac
839 ])
840
841 case $cf_cv_term_header in #(vi
842 term.h) #(vi
843         AC_DEFINE(HAVE_TERM_H)
844         ;;
845 ncurses/term.h) #(vi
846         AC_DEFINE(HAVE_NCURSES_TERM_H)
847         ;;
848 ncursesw/term.h)
849         AC_DEFINE(HAVE_NCURSESW_TERM_H)
850         ;;
851 esac
852 ])dnl
853 dnl ---------------------------------------------------------------------------
854 dnl CF_CURSES_UNCTRL_H version: 1 updated: 2011/04/09 18:19:55
855 dnl ------------------
856 dnl Any X/Open curses implementation must have unctrl.h, but ncurses packages
857 dnl may put it in a subdirectory (along with ncurses' other headers, of
858 dnl course).  Packages which put the headers in inconsistent locations are
859 dnl broken).
860 AC_DEFUN([CF_CURSES_UNCTRL_H],
861 [
862 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
863
864 AC_CACHE_CHECK(for unctrl.h, cf_cv_unctrl_header,[
865
866 # If we found <ncurses/curses.h>, look for <ncurses/unctrl.h>, but always look
867 # for <unctrl.h> if we do not find the variant.
868
869 cf_header_list="unctrl.h ncurses/unctrl.h ncursesw/unctrl.h"
870
871 case ${cf_cv_ncurses_header:-curses.h} in #(vi
872 */*)
873         cf_header_item=`echo ${cf_cv_ncurses_header:-curses.h} | sed -e 's%\..*%%' -e 's%/.*%/%'`unctrl.h
874         cf_header_list="$cf_header_item $cf_header_list"
875         ;;
876 esac
877
878 for cf_header in $cf_header_list
879 do
880         AC_TRY_COMPILE([
881 #include <${cf_cv_ncurses_header:-curses.h}>
882 #include <${cf_header}>],
883         [WINDOW *x],
884         [cf_cv_unctrl_header=$cf_header
885          break],
886         [cf_cv_unctrl_header=no])
887 done
888
889 case $cf_cv_unctrl_header in #(vi
890 no)
891         AC_MSG_WARN(unctrl.h header not found)
892         ;;
893 esac
894 ])
895
896 case $cf_cv_unctrl_header in #(vi
897 unctrl.h) #(vi
898         AC_DEFINE(HAVE_UNCTRL_H)
899         ;;
900 ncurses/unctrl.h) #(vi
901         AC_DEFINE(HAVE_NCURSES_UNCTRL_H)
902         ;;
903 ncursesw/unctrl.h)
904         AC_DEFINE(HAVE_NCURSESW_UNCTRL_H)
905         ;;
906 esac
907 ])dnl
908 dnl ---------------------------------------------------------------------------
909 dnl CF_CURSES_WACS_MAP version: 5 updated: 2011/01/15 11:28:59
910 dnl ------------------
911 dnl Check for likely values of wacs_map[].
912 AC_DEFUN([CF_CURSES_WACS_MAP],
913 [
914 AC_CACHE_CHECK(for wide alternate character set array, cf_cv_curses_wacs_map,[
915         cf_cv_curses_wacs_map=unknown
916         for name in wacs_map _wacs_map __wacs_map _nc_wacs _wacs_char
917         do
918         AC_TRY_LINK([
919 #ifndef _XOPEN_SOURCE_EXTENDED
920 #define _XOPEN_SOURCE_EXTENDED
921 #endif
922 #include <${cf_cv_ncurses_header:-curses.h}>],
923         [void *foo = &($name['k'])],
924         [cf_cv_curses_wacs_map=$name
925          break])
926         done])
927
928 test "$cf_cv_curses_wacs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_WACS_ARRAY,$cf_cv_curses_wacs_map)
929 ])dnl
930 dnl ---------------------------------------------------------------------------
931 dnl CF_CURSES_WACS_SYMBOLS version: 1 updated: 2011/01/15 11:28:59
932 dnl ----------------------
933 dnl Do a check to see if the WACS_xxx constants are defined compatibly with
934 dnl X/Open Curses.  In particular, NetBSD's implementation of the WACS_xxx
935 dnl constants is broken since those constants do not point to cchar_t's.
936 AC_DEFUN([CF_CURSES_WACS_SYMBOLS],
937 [
938 AC_REQUIRE([CF_CURSES_WACS_MAP])
939
940 AC_CACHE_CHECK(for wide alternate character constants, cf_cv_curses_wacs_symbols,[
941 cf_cv_curses_wacs_symbols=no
942 if test "$cf_cv_curses_wacs_map" != unknown
943 then
944         AC_TRY_LINK([
945 #ifndef _XOPEN_SOURCE_EXTENDED
946 #define _XOPEN_SOURCE_EXTENDED
947 #endif
948 #include <${cf_cv_ncurses_header:-curses.h}>],
949         [cchar_t *foo = WACS_PLUS;
950          $cf_cv_curses_wacs_map['k'] = *WACS_PLUS],
951         [cf_cv_curses_wacs_symbols=yes])
952 else
953         AC_TRY_LINK([
954 #ifndef _XOPEN_SOURCE_EXTENDED
955 #define _XOPEN_SOURCE_EXTENDED
956 #endif
957 #include <${cf_cv_ncurses_header:-curses.h}>],
958         [cchar_t *foo = WACS_PLUS],
959         [cf_cv_curses_wacs_symbols=yes])
960 fi
961 ])
962
963 test "$cf_cv_curses_wacs_symbols" != no && AC_DEFINE(CURSES_WACS_SYMBOLS)
964 ])dnl
965 dnl ---------------------------------------------------------------------------
966 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
967 dnl ----------
968 dnl "dirname" is not portable, so we fake it with a shell script.
969 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
970 dnl ---------------------------------------------------------------------------
971 dnl CF_DISABLE_ECHO version: 11 updated: 2009/12/13 13:16:57
972 dnl ---------------
973 dnl You can always use "make -n" to see the actual options, but it's hard to
974 dnl pick out/analyze warning messages when the compile-line is long.
975 dnl
976 dnl Sets:
977 dnl     ECHO_LT - symbol to control if libtool is verbose
978 dnl     ECHO_LD - symbol to prefix "cc -o" lines
979 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
980 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
981 dnl     ECHO_CC - symbol to put before any "cc" line
982 dnl
983 AC_DEFUN([CF_DISABLE_ECHO],[
984 AC_MSG_CHECKING(if you want to see long compiling messages)
985 CF_ARG_DISABLE(echo,
986         [  --disable-echo          display "compiling" commands],
987         [
988     ECHO_LT='--silent'
989     ECHO_LD='@echo linking [$]@;'
990     RULE_CC='@echo compiling [$]<'
991     SHOW_CC='@echo compiling [$]@'
992     ECHO_CC='@'
993 ],[
994     ECHO_LT=''
995     ECHO_LD=''
996     RULE_CC=''
997     SHOW_CC=''
998     ECHO_CC=''
999 ])
1000 AC_MSG_RESULT($enableval)
1001 AC_SUBST(ECHO_LT)
1002 AC_SUBST(ECHO_LD)
1003 AC_SUBST(RULE_CC)
1004 AC_SUBST(SHOW_CC)
1005 AC_SUBST(ECHO_CC)
1006 ])dnl
1007 dnl ---------------------------------------------------------------------------
1008 dnl CF_DISABLE_LEAKS version: 6 updated: 2010/07/23 04:14:32
1009 dnl ----------------
1010 dnl Combine no-leak checks with the libraries or tools that are used for the
1011 dnl checks.
1012 AC_DEFUN([CF_DISABLE_LEAKS],[
1013
1014 AC_REQUIRE([CF_WITH_DMALLOC])
1015 AC_REQUIRE([CF_WITH_DBMALLOC])
1016 AC_REQUIRE([CF_WITH_VALGRIND])
1017
1018 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1019 AC_ARG_ENABLE(leaks,
1020         [  --disable-leaks         test: free permanent memory, analyze leaks],
1021         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1022         : ${with_no_leaks:=no})
1023 AC_MSG_RESULT($with_no_leaks)
1024
1025 if test "$with_no_leaks" = yes ; then
1026         AC_DEFINE(NO_LEAKS)
1027         AC_DEFINE(YY_NO_LEAKS)
1028 fi
1029 ])dnl
1030 dnl ---------------------------------------------------------------------------
1031 dnl CF_ENABLE_WARNINGS version: 4 updated: 2009/07/26 17:53:03
1032 dnl ------------------
1033 dnl Configure-option to enable gcc warnings
1034 AC_DEFUN([CF_ENABLE_WARNINGS],[
1035 if ( test "$GCC" = yes || test "$GXX" = yes )
1036 then
1037 AC_MSG_CHECKING(if you want to turn on gcc warnings)
1038 CF_ARG_ENABLE(warnings,
1039         [  --enable-warnings       test: turn on gcc compiler warnings],
1040         [with_warnings=yes],
1041         [with_warnings=no])
1042 AC_MSG_RESULT($with_warnings)
1043 if test "$with_warnings" = "yes"
1044 then
1045         CF_GCC_ATTRIBUTES
1046         CF_GCC_WARNINGS
1047 fi
1048 fi
1049 ])dnl
1050 dnl ---------------------------------------------------------------------------
1051 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
1052 dnl ---------------
1053 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
1054 dnl prefer a standard location, and use -L options only if we do not find the
1055 dnl library in the standard library location(s).
1056 dnl     $1 = library name
1057 dnl     $2 = library class, usually the same as library name
1058 dnl     $3 = includes
1059 dnl     $4 = code fragment to compile/link
1060 dnl     $5 = corresponding function-name
1061 dnl     $6 = flag, nonnull if failure should not cause an error-exit
1062 dnl
1063 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
1064 dnl to use a -L option.
1065 AC_DEFUN([CF_FIND_LIBRARY],
1066 [
1067         eval 'cf_cv_have_lib_'$1'=no'
1068         cf_libdir=""
1069         AC_CHECK_FUNC($5,
1070                 eval 'cf_cv_have_lib_'$1'=yes',[
1071                 cf_save_LIBS="$LIBS"
1072                 AC_MSG_CHECKING(for $5 in -l$1)
1073                 LIBS="-l$1 $LIBS"
1074                 AC_TRY_LINK([$3],[$4],
1075                         [AC_MSG_RESULT(yes)
1076                          eval 'cf_cv_have_lib_'$1'=yes'
1077                         ],
1078                         [AC_MSG_RESULT(no)
1079                         CF_LIBRARY_PATH(cf_search,$2)
1080                         for cf_libdir in $cf_search
1081                         do
1082                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
1083                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
1084                                 AC_TRY_LINK([$3],[$4],
1085                                         [AC_MSG_RESULT(yes)
1086                                          eval 'cf_cv_have_lib_'$1'=yes'
1087                                          break],
1088                                         [AC_MSG_RESULT(no)
1089                                          LIBS="$cf_save_LIBS"])
1090                         done
1091                         ])
1092                 ])
1093 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
1094 ifelse($6,,[
1095 if test $cf_found_library = no ; then
1096         AC_MSG_ERROR(Cannot link $1 library)
1097 fi
1098 ])
1099 ])dnl
1100 dnl ---------------------------------------------------------------------------
1101 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1102 dnl ---------------
1103 dnl Find a library (specifically the linkage used in the code fragment),
1104 dnl searching for it if it is not already in the library path.
1105 dnl See also CF_ADD_SEARCHPATH.
1106 dnl
1107 dnl Parameters (4-on are optional):
1108 dnl     $1 = headers for library entrypoint
1109 dnl     $2 = code fragment for library entrypoint
1110 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1111 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1112 dnl     $5 = action to perform if not successful
1113 dnl     $6 = module name, if not the same as the library name
1114 dnl     $7 = extra libraries
1115 dnl
1116 dnl Sets these variables:
1117 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1118 dnl     $cf_cv_header_path_$3 - include-directory if needed
1119 dnl     $cf_cv_library_path_$3 - library-directory if needed
1120 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1121 AC_DEFUN([CF_FIND_LINKAGE],[
1122
1123 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1124 # will be set on completion of the AC_TRY_LINK below.
1125 cf_cv_header_path_$3=
1126 cf_cv_library_path_$3=
1127
1128 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1129
1130 cf_save_LIBS="$LIBS"
1131
1132 AC_TRY_LINK([$1],[$2],[
1133         cf_cv_find_linkage_$3=yes
1134         cf_cv_header_path_$3=/usr/include
1135         cf_cv_library_path_$3=/usr/lib
1136 ],[
1137
1138 LIBS="-l$3 $7 $cf_save_LIBS"
1139
1140 AC_TRY_LINK([$1],[$2],[
1141         cf_cv_find_linkage_$3=yes
1142         cf_cv_header_path_$3=/usr/include
1143         cf_cv_library_path_$3=/usr/lib
1144         cf_cv_library_file_$3="-l$3"
1145 ],[
1146         cf_cv_find_linkage_$3=no
1147         LIBS="$cf_save_LIBS"
1148
1149     CF_VERBOSE(find linkage for $3 library)
1150     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1151
1152     cf_save_CPPFLAGS="$CPPFLAGS"
1153     cf_test_CPPFLAGS="$CPPFLAGS"
1154
1155     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1156     for cf_cv_header_path_$3 in $cf_search
1157     do
1158       if test -d $cf_cv_header_path_$3 ; then
1159         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1160         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1161         AC_TRY_COMPILE([$1],[$2],[
1162             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1163             cf_cv_find_linkage_$3=maybe
1164             cf_test_CPPFLAGS="$CPPFLAGS"
1165             break],[
1166             CPPFLAGS="$cf_save_CPPFLAGS"
1167             ])
1168       fi
1169     done
1170
1171     if test "$cf_cv_find_linkage_$3" = maybe ; then
1172
1173       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1174
1175       cf_save_LIBS="$LIBS"
1176       cf_save_LDFLAGS="$LDFLAGS"
1177
1178       ifelse([$6],,,[
1179         CPPFLAGS="$cf_test_CPPFLAGS"
1180         LIBS="-l$3 $7 $cf_save_LIBS"
1181         AC_TRY_LINK([$1],[$2],[
1182             CF_VERBOSE(... found $3 library in system)
1183             cf_cv_find_linkage_$3=yes])
1184             CPPFLAGS="$cf_save_CPPFLAGS"
1185             LIBS="$cf_save_LIBS"
1186             ])
1187
1188       if test "$cf_cv_find_linkage_$3" != yes ; then
1189         CF_LIBRARY_PATH(cf_search,$3)
1190         for cf_cv_library_path_$3 in $cf_search
1191         do
1192           if test -d $cf_cv_library_path_$3 ; then
1193             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1194             CPPFLAGS="$cf_test_CPPFLAGS"
1195             LIBS="-l$3 $7 $cf_save_LIBS"
1196             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1197             AC_TRY_LINK([$1],[$2],[
1198                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1199                 cf_cv_find_linkage_$3=yes
1200                 cf_cv_library_file_$3="-l$3"
1201                 break],[
1202                 CPPFLAGS="$cf_save_CPPFLAGS"
1203                 LIBS="$cf_save_LIBS"
1204                 LDFLAGS="$cf_save_LDFLAGS"
1205                 ])
1206           fi
1207         done
1208         CPPFLAGS="$cf_save_CPPFLAGS"
1209         LDFLAGS="$cf_save_LDFLAGS"
1210       fi
1211
1212     else
1213       cf_cv_find_linkage_$3=no
1214     fi
1215     ],$7)
1216 ])
1217
1218 LIBS="$cf_save_LIBS"
1219
1220 if test "$cf_cv_find_linkage_$3" = yes ; then
1221 ifelse([$4],,[
1222         CF_ADD_INCDIR($cf_cv_header_path_$3)
1223         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1224         CF_ADD_LIB($3)
1225 ],[$4])
1226 else
1227 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1228 fi
1229 ])dnl
1230 dnl ---------------------------------------------------------------------------
1231 dnl CF_FUNC_CURSES_VERSION version: 5 updated: 2010/10/23 15:54:49
1232 dnl ----------------------
1233 dnl Solaris has a data item 'curses_version', which confuses AC_CHECK_FUNCS.
1234 dnl It's a character string "SVR4", not documented.
1235 AC_DEFUN([CF_FUNC_CURSES_VERSION],
1236 [
1237 AC_CACHE_CHECK(for function curses_version, cf_cv_func_curses_version,[
1238 AC_TRY_RUN([
1239 #include <${cf_cv_ncurses_header:-curses.h}>
1240 int main()
1241 {
1242         char temp[1024];
1243         sprintf(temp, "%s\n", curses_version());
1244         ${cf_cv_main_return:-return}(0);
1245 }]
1246 ,[cf_cv_func_curses_version=yes]
1247 ,[cf_cv_func_curses_version=no]
1248 ,[cf_cv_func_curses_version=unknown])
1249 rm -f core])
1250 test "$cf_cv_func_curses_version" = yes && AC_DEFINE(HAVE_CURSES_VERSION)
1251 ])
1252 dnl ---------------------------------------------------------------------------
1253 dnl CF_GCC_ATTRIBUTES version: 14 updated: 2010/10/23 15:52:32
1254 dnl -----------------
1255 dnl Test for availability of useful gcc __attribute__ directives to quiet
1256 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1257 dnl to documentation, unrecognized directives cause older compilers to barf.
1258 AC_DEFUN([CF_GCC_ATTRIBUTES],
1259 [
1260 if test "$GCC" = yes
1261 then
1262 cat > conftest.i <<EOF
1263 #ifndef GCC_PRINTF
1264 #define GCC_PRINTF 0
1265 #endif
1266 #ifndef GCC_SCANF
1267 #define GCC_SCANF 0
1268 #endif
1269 #ifndef GCC_NORETURN
1270 #define GCC_NORETURN /* nothing */
1271 #endif
1272 #ifndef GCC_UNUSED
1273 #define GCC_UNUSED /* nothing */
1274 #endif
1275 EOF
1276 if test "$GCC" = yes
1277 then
1278         AC_CHECKING([for $CC __attribute__ directives])
1279 cat > conftest.$ac_ext <<EOF
1280 #line __oline__ "${as_me:-configure}"
1281 #include "confdefs.h"
1282 #include "conftest.h"
1283 #include "conftest.i"
1284 #if     GCC_PRINTF
1285 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1286 #else
1287 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1288 #endif
1289 #if     GCC_SCANF
1290 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1291 #else
1292 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1293 #endif
1294 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1295 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1296 extern void foo(void) GCC_NORETURN;
1297 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1298 EOF
1299         cf_printf_attribute=no
1300         cf_scanf_attribute=no
1301         for cf_attribute in scanf printf unused noreturn
1302         do
1303                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1304                 cf_directive="__attribute__(($cf_attribute))"
1305                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1306
1307                 case $cf_attribute in #(vi
1308                 printf) #(vi
1309                         cf_printf_attribute=yes
1310                         cat >conftest.h <<EOF
1311 #define GCC_$cf_ATTRIBUTE 1
1312 EOF
1313                         ;;
1314                 scanf) #(vi
1315                         cf_scanf_attribute=yes
1316                         cat >conftest.h <<EOF
1317 #define GCC_$cf_ATTRIBUTE 1
1318 EOF
1319                         ;;
1320                 *) #(vi
1321                         cat >conftest.h <<EOF
1322 #define GCC_$cf_ATTRIBUTE $cf_directive
1323 EOF
1324                         ;;
1325                 esac
1326
1327                 if AC_TRY_EVAL(ac_compile); then
1328                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1329                         cat conftest.h >>confdefs.h
1330                         case $cf_attribute in #(vi
1331                         printf) #(vi
1332                                 if test "$cf_printf_attribute" = no ; then
1333                                         cat >>confdefs.h <<EOF
1334 #define GCC_PRINTFLIKE(fmt,var) /* nothing */
1335 EOF
1336                                 else
1337                                         cat >>confdefs.h <<EOF
1338 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1339 EOF
1340                                 fi
1341                                 ;;
1342                         scanf) #(vi
1343                                 if test "$cf_scanf_attribute" = no ; then
1344                                         cat >>confdefs.h <<EOF
1345 #define GCC_SCANFLIKE(fmt,var) /* nothing */
1346 EOF
1347                                 else
1348                                         cat >>confdefs.h <<EOF
1349 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1350 EOF
1351                                 fi
1352                                 ;;
1353                         esac
1354                 fi
1355         done
1356 else
1357         fgrep define conftest.i >>confdefs.h
1358 fi
1359 rm -rf conftest*
1360 fi
1361 ])dnl
1362 dnl ---------------------------------------------------------------------------
1363 dnl CF_GCC_VERSION version: 5 updated: 2010/04/24 11:02:31
1364 dnl --------------
1365 dnl Find version of gcc
1366 AC_DEFUN([CF_GCC_VERSION],[
1367 AC_REQUIRE([AC_PROG_CC])
1368 GCC_VERSION=none
1369 if test "$GCC" = yes ; then
1370         AC_MSG_CHECKING(version of $CC)
1371         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1372         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1373         AC_MSG_RESULT($GCC_VERSION)
1374 fi
1375 ])dnl
1376 dnl ---------------------------------------------------------------------------
1377 dnl CF_GCC_WARNINGS version: 27 updated: 2010/10/23 15:52:32
1378 dnl ---------------
1379 dnl Check if the compiler supports useful warning options.  There's a few that
1380 dnl we don't use, simply because they're too noisy:
1381 dnl
1382 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1383 dnl     -Wredundant-decls (system headers make this too noisy)
1384 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1385 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1386 dnl             is enabled for ncurses using "--enable-const".
1387 dnl     -pedantic
1388 dnl
1389 dnl Parameter:
1390 dnl     $1 is an optional list of gcc warning flags that a particular
1391 dnl             application might want to use, e.g., "no-unused" for
1392 dnl             -Wno-unused
1393 dnl Special:
1394 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1395 dnl
1396 AC_DEFUN([CF_GCC_WARNINGS],
1397 [
1398 AC_REQUIRE([CF_GCC_VERSION])
1399 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1400
1401 cat > conftest.$ac_ext <<EOF
1402 #line __oline__ "${as_me:-configure}"
1403 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1404 EOF
1405
1406 if test "$INTEL_COMPILER" = yes
1407 then
1408 # The "-wdXXX" options suppress warnings:
1409 # remark #1419: external declaration in primary source file
1410 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1411 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1412 # remark #193: zero used for undefined preprocessing identifier
1413 # remark #593: variable "curs_sb_left_arrow" was set but never used
1414 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1415 # remark #869: parameter "tw" was never referenced
1416 # remark #981: operands are evaluated in unspecified order
1417 # warning #279: controlling expression is constant
1418
1419         AC_CHECKING([for $CC warning options])
1420         cf_save_CFLAGS="$CFLAGS"
1421         EXTRA_CFLAGS="-Wall"
1422         for cf_opt in \
1423                 wd1419 \
1424                 wd1683 \
1425                 wd1684 \
1426                 wd193 \
1427                 wd593 \
1428                 wd279 \
1429                 wd810 \
1430                 wd869 \
1431                 wd981
1432         do
1433                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1434                 if AC_TRY_EVAL(ac_compile); then
1435                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1436                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1437                 fi
1438         done
1439         CFLAGS="$cf_save_CFLAGS"
1440
1441 elif test "$GCC" = yes
1442 then
1443         AC_CHECKING([for $CC warning options])
1444         cf_save_CFLAGS="$CFLAGS"
1445         EXTRA_CFLAGS=
1446         cf_warn_CONST=""
1447         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1448         for cf_opt in W Wall \
1449                 Wbad-function-cast \
1450                 Wcast-align \
1451                 Wcast-qual \
1452                 Winline \
1453                 Wmissing-declarations \
1454                 Wmissing-prototypes \
1455                 Wnested-externs \
1456                 Wpointer-arith \
1457                 Wshadow \
1458                 Wstrict-prototypes \
1459                 Wundef $cf_warn_CONST $1
1460         do
1461                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1462                 if AC_TRY_EVAL(ac_compile); then
1463                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1464                         case $cf_opt in #(vi
1465                         Wcast-qual) #(vi
1466                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1467                                 ;;
1468                         Winline) #(vi
1469                                 case $GCC_VERSION in
1470                                 [[34]].*)
1471                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1472                                         continue;;
1473                                 esac
1474                                 ;;
1475                         esac
1476                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1477                 fi
1478         done
1479         CFLAGS="$cf_save_CFLAGS"
1480 fi
1481 rm -rf conftest*
1482
1483 AC_SUBST(EXTRA_CFLAGS)
1484 ])dnl
1485 dnl ---------------------------------------------------------------------------
1486 dnl CF_GETOPT_HEADER version: 4 updated: 2009/08/31 20:07:52
1487 dnl ----------------
1488 dnl Check for getopt's variables which are commonly defined in stdlib.h,
1489 dnl unistd.h or (nonstandard) in getopt.h
1490 AC_DEFUN([CF_GETOPT_HEADER],
1491 [
1492 AC_HAVE_HEADERS(unistd.h getopt.h)
1493 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
1494 cf_cv_getopt_header=none
1495 for cf_header in stdio.h stdlib.h unistd.h getopt.h
1496 do
1497 AC_TRY_COMPILE([
1498 #include <$cf_header>],
1499 [int x = optind; char *y = optarg],
1500 [cf_cv_getopt_header=$cf_header
1501  break])
1502 done
1503 ])
1504 if test $cf_cv_getopt_header != none ; then
1505         AC_DEFINE(HAVE_GETOPT_HEADER)
1506 fi
1507 ])dnl
1508 dnl ---------------------------------------------------------------------------
1509 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
1510 dnl -------------
1511 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1512 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1513 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1514 dnl since it is interwoven with GNU extensions.
1515 dnl
1516 dnl Well, yes we could work around it...
1517 AC_DEFUN([CF_GNU_SOURCE],
1518 [
1519 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1520 AC_TRY_COMPILE([#include <sys/types.h>],[
1521 #ifndef _XOPEN_SOURCE
1522 make an error
1523 #endif],
1524         [cf_cv_gnu_source=no],
1525         [cf_save="$CPPFLAGS"
1526          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1527          AC_TRY_COMPILE([#include <sys/types.h>],[
1528 #ifdef _XOPEN_SOURCE
1529 make an error
1530 #endif],
1531         [cf_cv_gnu_source=no],
1532         [cf_cv_gnu_source=yes])
1533         CPPFLAGS="$cf_save"
1534         ])
1535 ])
1536 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1537 ])dnl
1538 dnl ---------------------------------------------------------------------------
1539 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
1540 dnl --------------
1541 dnl Construct a search-list of directories for a nonstandard header-file
1542 dnl
1543 dnl Parameters
1544 dnl     $1 = the variable to return as result
1545 dnl     $2 = the package name
1546 AC_DEFUN([CF_HEADER_PATH],
1547 [
1548 $1=
1549
1550 # collect the current set of include-directories from compiler flags
1551 cf_header_path_list=""
1552 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1553         for cf_header_path in $CPPFLAGS $CFLAGS
1554         do
1555                 case $cf_header_path in #(vi
1556                 -I*)
1557                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1558                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1559                         cf_header_path_list="$cf_header_path_list [$]$1"
1560                         ;;
1561                 esac
1562         done
1563 fi
1564
1565 # add the variations for the package we are looking for
1566 CF_SUBDIR_PATH($1,$2,include)
1567
1568 test "$includedir" != NONE && \
1569 test "$includedir" != "/usr/include" && \
1570 test -d "$includedir" && {
1571         test -d $includedir &&    $1="[$]$1 $includedir"
1572         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1573 }
1574
1575 test "$oldincludedir" != NONE && \
1576 test "$oldincludedir" != "/usr/include" && \
1577 test -d "$oldincludedir" && {
1578         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1579         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1580 }
1581
1582 $1="[$]$1 $cf_header_path_list"
1583 ])dnl
1584 dnl ---------------------------------------------------------------------------
1585 dnl CF_INHERIT_SCRIPT version: 2 updated: 2003/03/01 23:50:42
1586 dnl -----------------
1587 dnl If we do not have a given script, look for it in the parent directory.
1588 AC_DEFUN([CF_INHERIT_SCRIPT],
1589 [
1590 test -f $1 || ( test -f ../$1 && cp ../$1 ./ )
1591 ])dnl
1592 dnl ---------------------------------------------------------------------------
1593 dnl CF_INTEL_COMPILER version: 4 updated: 2010/05/26 05:38:42
1594 dnl -----------------
1595 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1596 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1597 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1598 dnl
1599 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1600 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1601 dnl the wrappers for gcc and g++ warnings.
1602 dnl
1603 dnl $1 = GCC (default) or GXX
1604 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1605 dnl $3 = CFLAGS (default) or CXXFLAGS
1606 AC_DEFUN([CF_INTEL_COMPILER],[
1607 ifelse([$2],,INTEL_COMPILER,[$2])=no
1608
1609 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1610         case $host_os in
1611         linux*|gnu*)
1612                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1613                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1614                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1615                 AC_TRY_COMPILE([],[
1616 #ifdef __INTEL_COMPILER
1617 #else
1618 make an error
1619 #endif
1620 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1621 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
1622 ],[])
1623                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1624                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1625                 ;;
1626         esac
1627 fi
1628 ])dnl
1629 dnl ---------------------------------------------------------------------------
1630 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
1631 dnl ---------------
1632 dnl Construct a search-list of directories for a nonstandard library-file
1633 dnl
1634 dnl Parameters
1635 dnl     $1 = the variable to return as result
1636 dnl     $2 = the package name
1637 AC_DEFUN([CF_LIBRARY_PATH],
1638 [
1639 $1=
1640 cf_library_path_list=""
1641 if test -n "${LDFLAGS}${LIBS}" ; then
1642         for cf_library_path in $LDFLAGS $LIBS
1643         do
1644                 case $cf_library_path in #(vi
1645                 -L*)
1646                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1647                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1648                         cf_library_path_list="$cf_library_path_list [$]$1"
1649                         ;;
1650                 esac
1651         done
1652 fi
1653
1654 CF_SUBDIR_PATH($1,$2,lib)
1655
1656 $1="$cf_library_path_list [$]$1"
1657 ])dnl
1658 dnl ---------------------------------------------------------------------------
1659 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
1660 dnl ------------
1661 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
1662 dnl a monocase filesystem.
1663 AC_DEFUN([CF_MAKE_TAGS],[
1664 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
1665
1666 AC_CHECK_PROGS(CTAGS, exctags ctags)
1667 AC_CHECK_PROGS(ETAGS, exetags etags)
1668
1669 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
1670
1671 if test "$cf_cv_mixedcase" = yes ; then
1672         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
1673 else
1674         MAKE_UPPER_TAGS=no
1675 fi
1676
1677 if test "$MAKE_UPPER_TAGS" = yes ; then
1678         MAKE_UPPER_TAGS=
1679 else
1680         MAKE_UPPER_TAGS="#"
1681 fi
1682
1683 if test "$MAKE_LOWER_TAGS" = yes ; then
1684         MAKE_LOWER_TAGS=
1685 else
1686         MAKE_LOWER_TAGS="#"
1687 fi
1688
1689 AC_SUBST(CTAGS)
1690 AC_SUBST(ETAGS)
1691
1692 AC_SUBST(MAKE_UPPER_TAGS)
1693 AC_SUBST(MAKE_LOWER_TAGS)
1694 ])dnl
1695 dnl ---------------------------------------------------------------------------
1696 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
1697 dnl -----------
1698 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
1699 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
1700 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
1701 AC_DEFUN([CF_MATH_LIB],
1702 [
1703 AC_CACHE_CHECK(if -lm needed for math functions,
1704         cf_cv_need_libm,[
1705         AC_TRY_LINK([
1706         #include <stdio.h>
1707         #include <math.h>
1708         ],
1709         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
1710         [cf_cv_need_libm=no],
1711         [cf_cv_need_libm=yes])])
1712 if test "$cf_cv_need_libm" = yes
1713 then
1714 ifelse($1,,[
1715         CF_ADD_LIB(m)
1716 ],[$1=-lm])
1717 fi
1718 ])
1719 dnl ---------------------------------------------------------------------------
1720 dnl CF_MIN_GETCCHAR version: 3 updated: 2010/10/23 15:54:49
1721 dnl ---------------
1722 dnl CF_MIN_GETCCHAR
1723 dnl Check whether getcchar's return value counts the trailing null in a wchar_t
1724 dnl string, or not.  X/Open says it does, but Tru64 and Solaris do not do this.
1725 AC_DEFUN([CF_MIN_GETCCHAR],[
1726 AC_CACHE_CHECK(if getcchar counts trailing null,cf_cv_min_getcchar,[
1727 AC_TRY_RUN([
1728 #include <stdlib.h>
1729 #include <stdarg.h>
1730 #include <${cf_cv_ncurses_header:-curses.h}>
1731
1732 int main()
1733 {
1734         wchar_t data[2];
1735         cchar_t temp[2];
1736         int count;
1737         data[0] = L'\0';
1738     setcchar(temp, data, 0, 0, (void *)0);
1739         count = getcchar(temp, (wchar_t *)0, (attr_t *)0, (short *)0, (void *)0);
1740         ${cf_cv_main_return:-return}(count != 0);
1741 }],
1742         [cf_cv_min_getcchar=no],
1743         [cf_cv_min_getcchar=yes],
1744         [cf_cv_min_getcchar=yes])
1745 ])
1746 if test "$cf_cv_min_getcchar" = yes ; then
1747         AC_DEFINE(MIN_GETCCHAR,1)
1748 fi
1749 ])dnl
1750 dnl ---------------------------------------------------------------------------
1751 dnl CF_MIXEDCASE_FILENAMES version: 3 updated: 2003/09/20 17:07:55
1752 dnl ----------------------
1753 dnl Check if the file-system supports mixed-case filenames.  If we're able to
1754 dnl create a lowercase name and see it as uppercase, it doesn't support that.
1755 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
1756 [
1757 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
1758 if test "$cross_compiling" = yes ; then
1759         case $target_alias in #(vi
1760         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-mingw32*|*-uwin*) #(vi
1761                 cf_cv_mixedcase=no
1762                 ;;
1763         *)
1764                 cf_cv_mixedcase=yes
1765                 ;;
1766         esac
1767 else
1768         rm -f conftest CONFTEST
1769         echo test >conftest
1770         if test -f CONFTEST ; then
1771                 cf_cv_mixedcase=no
1772         else
1773                 cf_cv_mixedcase=yes
1774         fi
1775         rm -f conftest CONFTEST
1776 fi
1777 ])
1778 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES)
1779 ])dnl
1780 dnl ---------------------------------------------------------------------------
1781 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
1782 dnl ----------
1783 dnl Write a debug message to config.log, along with the line number in the
1784 dnl configure script.
1785 AC_DEFUN([CF_MSG_LOG],[
1786 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
1787 ])dnl
1788 dnl ---------------------------------------------------------------------------
1789 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
1790 dnl -------------------
1791 dnl Check if we can compile with ncurses' header file
1792 dnl $1 is the cache variable to set
1793 dnl $2 is the header-file to include
1794 dnl $3 is the root name (ncurses or ncursesw)
1795 AC_DEFUN([CF_NCURSES_CC_CHECK],[
1796         AC_TRY_COMPILE([
1797 ]ifelse($3,ncursesw,[
1798 #define _XOPEN_SOURCE_EXTENDED
1799 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
1800 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
1801 ])[
1802 #include <$2>],[
1803 #ifdef NCURSES_VERSION
1804 ]ifelse($3,ncursesw,[
1805 #ifndef WACS_BSSB
1806         make an error
1807 #endif
1808 ])[
1809 printf("%s\n", NCURSES_VERSION);
1810 #else
1811 #ifdef __NCURSES_H
1812 printf("old\n");
1813 #else
1814         make an error
1815 #endif
1816 #endif
1817         ]
1818         ,[$1=$2]
1819         ,[$1=no])
1820 ])dnl
1821 dnl ---------------------------------------------------------------------------
1822 dnl CF_NCURSES_CONFIG version: 8 updated: 2010/07/08 05:17:30
1823 dnl -----------------
1824 dnl Tie together the configure-script macros for ncurses.
1825 dnl Prefer the "-config" script from ncurses 6.x, to simplify analysis.
1826 dnl Allow that to be overridden using the $NCURSES_CONFIG environment variable.
1827 dnl
1828 dnl $1 is the root library name (default: "ncurses")
1829 AC_DEFUN([CF_NCURSES_CONFIG],
1830 [
1831 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
1832
1833 echo "Looking for ${cf_ncuconfig_root}-config"
1834 AC_PATH_PROGS(NCURSES_CONFIG,${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config,none)
1835
1836 if test "$NCURSES_CONFIG" != none ; then
1837
1838 CPPFLAGS="$CPPFLAGS `$NCURSES_CONFIG --cflags`"
1839 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
1840
1841 # even with config script, some packages use no-override for curses.h
1842 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
1843
1844 dnl like CF_NCURSES_CPPFLAGS
1845 AC_DEFINE(NCURSES)
1846
1847 dnl like CF_NCURSES_LIBS
1848 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
1849 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
1850
1851 dnl like CF_NCURSES_VERSION
1852 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
1853
1854 else
1855
1856 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
1857 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
1858
1859 fi
1860 ])dnl
1861 dnl ---------------------------------------------------------------------------
1862 dnl CF_NCURSES_CPPFLAGS version: 20 updated: 2010/11/20 17:02:38
1863 dnl -------------------
1864 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
1865 dnl the CPPFLAGS variable so we can include its header.
1866 dnl
1867 dnl The header files may be installed as either curses.h, or ncurses.h (would
1868 dnl be obsolete, except that some packagers prefer this name to distinguish it
1869 dnl from a "native" curses implementation).  If not installed for overwrite,
1870 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
1871 dnl /usr/include/ncurses), but someone may have installed overwriting the
1872 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
1873 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
1874 dnl the header.
1875 dnl
1876 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
1877 dnl is already in the include-path, don't even bother with this, since we cannot
1878 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
1879 dnl
1880 dnl The optional parameter gives the root name of the library, in case it is
1881 dnl not installed as the default curses library.  That is how the
1882 dnl wide-character version of ncurses is installed.
1883 AC_DEFUN([CF_NCURSES_CPPFLAGS],
1884 [AC_REQUIRE([CF_WITH_CURSES_DIR])
1885
1886 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
1887 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
1888
1889 test -n "$cf_cv_curses_dir" && \
1890 test "$cf_cv_curses_dir" != "no" && { \
1891   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
1892 }
1893
1894 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
1895         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
1896         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
1897         for cf_header in $cf_header_list
1898         do
1899                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
1900                 test "$cf_cv_ncurses_h" != no && break
1901         done
1902 ])
1903
1904 CF_NCURSES_HEADER
1905 CF_TERM_HEADER
1906
1907 # some applications need this, but should check for NCURSES_VERSION
1908 AC_DEFINE(NCURSES)
1909
1910 CF_NCURSES_VERSION
1911 ])dnl
1912 dnl ---------------------------------------------------------------------------
1913 dnl CF_NCURSES_EXT_FUNCS version: 3 updated: 2010/11/13 19:43:23
1914 dnl --------------------
1915 dnl Since 2007/11/17, ncurses has defined NCURSES_EXT_FUNCS; earlier versions
1916 dnl may provide these functions.  Define the symbol if it is not defined, and
1917 dnl if it is valid.
1918 AC_DEFUN([CF_NCURSES_EXT_FUNCS],
1919 [
1920 AC_CACHE_CHECK(for ncurses extended functions,cf_cv_ncurses_ext_funcs,[
1921 AC_TRY_COMPILE([
1922 #include <${cf_cv_ncurses_header:-curses.h}>],
1923 [
1924 int x = NCURSES_EXT_FUNCS
1925 ],[cf_cv_ncurses_ext_funcs=defined],[
1926 AC_TRY_LINK([
1927 #include <${cf_cv_ncurses_header:-curses.h}>],
1928 [
1929         (void) assume_default_colors (0, 0);
1930         (void) curses_version ();
1931         (void) define_key (0, 0);
1932         (void) is_term_resized (0, 0);
1933         (void) key_defined (0);
1934         (void) keybound (0, 0);
1935         (void) keyok (0, 0);
1936         (void) resize_term (0, 0);
1937         (void) resizeterm (0, 0);
1938         (void) use_default_colors ();
1939         (void) use_extended_names (0);
1940         (void) wresize (0, 0, 0);],
1941         [cf_cv_ncurses_ext_funcs=yes],
1942         [cf_cv_ncurses_ext_funcs=no])
1943 ])
1944 ])
1945 test "$cf_cv_ncurses_ext_funcs" = yes && AC_DEFINE(NCURSES_EXT_FUNCS)
1946 ])dnl
1947 dnl ---------------------------------------------------------------------------
1948 dnl CF_NCURSES_HEADER version: 2 updated: 2008/03/23 14:48:54
1949 dnl -----------------
1950 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
1951 dnl variations of ncurses' installs.
1952 dnl
1953 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
1954 AC_DEFUN([CF_NCURSES_HEADER],[
1955
1956 if test "$cf_cv_ncurses_h" != no ; then
1957         cf_cv_ncurses_header=$cf_cv_ncurses_h
1958 else
1959
1960 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
1961         test -n "$verbose" && echo
1962         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
1963         test -n "$verbose" && echo search path $cf_search
1964         cf_save2_CPPFLAGS="$CPPFLAGS"
1965         for cf_incdir in $cf_search
1966         do
1967                 CF_ADD_INCDIR($cf_incdir)
1968                 for cf_header in \
1969                         ncurses.h \
1970                         curses.h
1971                 do
1972                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
1973                         if test "$cf_cv_ncurses_h2" != no ; then
1974                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
1975                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
1976                                 break
1977                         fi
1978                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
1979                 done
1980                 CPPFLAGS="$cf_save2_CPPFLAGS"
1981                 test "$cf_cv_ncurses_h2" != no && break
1982         done
1983         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
1984         ])
1985
1986         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
1987         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
1988         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
1989                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
1990         fi
1991         CF_ADD_INCDIR($cf_1st_incdir)
1992
1993 fi
1994
1995 # Set definitions to allow ifdef'ing for ncurses.h
1996
1997 case $cf_cv_ncurses_header in # (vi
1998 *ncurses.h)
1999         AC_DEFINE(HAVE_NCURSES_H)
2000         ;;
2001 esac
2002
2003 case $cf_cv_ncurses_header in # (vi
2004 ncurses/curses.h|ncurses/ncurses.h)
2005         AC_DEFINE(HAVE_NCURSES_NCURSES_H)
2006         ;;
2007 ncursesw/curses.h|ncursesw/ncurses.h)
2008         AC_DEFINE(HAVE_NCURSESW_NCURSES_H)
2009         ;;
2010 esac
2011
2012 ])dnl
2013 dnl ---------------------------------------------------------------------------
2014 dnl CF_NCURSES_LIBS version: 16 updated: 2010/11/20 17:02:38
2015 dnl ---------------
2016 dnl Look for the ncurses library.  This is a little complicated on Linux,
2017 dnl because it may be linked with the gpm (general purpose mouse) library.
2018 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2019 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2020 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2021 dnl and the linker will record a dependency.
2022 dnl
2023 dnl The optional parameter gives the root name of the library, in case it is
2024 dnl not installed as the default curses library.  That is how the
2025 dnl wide-character version of ncurses is installed.
2026 AC_DEFUN([CF_NCURSES_LIBS],
2027 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2028
2029 cf_nculib_root=ifelse($1,,ncurses,$1)
2030         # This works, except for the special case where we find gpm, but
2031         # ncurses is in a nonstandard location via $LIBS, and we really want
2032         # to link gpm.
2033 cf_ncurses_LIBS=""
2034 cf_ncurses_SAVE="$LIBS"
2035 AC_CHECK_LIB(gpm,Gpm_Open,
2036         [AC_CHECK_LIB(gpm,initscr,
2037                 [LIBS="$cf_ncurses_SAVE"],
2038                 [cf_ncurses_LIBS="-lgpm"])])
2039
2040 case $host_os in #(vi
2041 freebsd*)
2042         # This is only necessary if you are linking against an obsolete
2043         # version of ncurses (but it should do no harm, since it's static).
2044         if test "$cf_nculib_root" = ncurses ; then
2045                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2046         fi
2047         ;;
2048 esac
2049
2050 CF_ADD_LIBS($cf_ncurses_LIBS)
2051
2052 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2053 then
2054         CF_ADD_LIBS(-l$cf_nculib_root)
2055 else
2056         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2057                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2058                 [initscr()],
2059                 initscr)
2060 fi
2061
2062 if test -n "$cf_ncurses_LIBS" ; then
2063         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2064         cf_ncurses_SAVE="$LIBS"
2065         for p in $cf_ncurses_LIBS ; do
2066                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2067                 if test "$q" != "$LIBS" ; then
2068                         LIBS="$q"
2069                 fi
2070         done
2071         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2072                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2073                 [AC_MSG_RESULT(yes)],
2074                 [AC_MSG_RESULT(no)
2075                  LIBS="$cf_ncurses_SAVE"])
2076 fi
2077
2078 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2079 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2080 ])dnl
2081 dnl ---------------------------------------------------------------------------
2082 dnl CF_NCURSES_VERSION version: 13 updated: 2010/10/23 15:54:49
2083 dnl ------------------
2084 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2085 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2086 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2087 AC_DEFUN([CF_NCURSES_VERSION],
2088 [
2089 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2090 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2091         cf_cv_ncurses_version=no
2092         cf_tempfile=out$$
2093         rm -f $cf_tempfile
2094         AC_TRY_RUN([
2095 #include <${cf_cv_ncurses_header:-curses.h}>
2096 #include <stdio.h>
2097 int main()
2098 {
2099         FILE *fp = fopen("$cf_tempfile", "w");
2100 #ifdef NCURSES_VERSION
2101 # ifdef NCURSES_VERSION_PATCH
2102         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2103 # else
2104         fprintf(fp, "%s\n", NCURSES_VERSION);
2105 # endif
2106 #else
2107 # ifdef __NCURSES_H
2108         fprintf(fp, "old\n");
2109 # else
2110         make an error
2111 # endif
2112 #endif
2113         ${cf_cv_main_return:-return}(0);
2114 }],[
2115         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2116
2117         # This will not work if the preprocessor splits the line after the
2118         # Autoconf token.  The 'unproto' program does that.
2119         cat > conftest.$ac_ext <<EOF
2120 #include <${cf_cv_ncurses_header:-curses.h}>
2121 #undef Autoconf
2122 #ifdef NCURSES_VERSION
2123 Autoconf NCURSES_VERSION
2124 #else
2125 #ifdef __NCURSES_H
2126 Autoconf "old"
2127 #endif
2128 ;
2129 #endif
2130 EOF
2131         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2132         AC_TRY_EVAL(cf_try)
2133         if test -f conftest.out ; then
2134                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2135                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2136                 rm -f conftest.out
2137         fi
2138 ])
2139         rm -f $cf_tempfile
2140 ])
2141 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES)
2142 ])dnl
2143 dnl ---------------------------------------------------------------------------
2144 dnl CF_NCURSES_WRAP_PREFIX version: 1 updated: 2009/03/28 16:08:10
2145 dnl ----------------------
2146 dnl Check for ncurses "wrap-prefix" used for public variables which have been
2147 dnl wrapped with a function to help with concurrency control.
2148 AC_DEFUN([CF_NCURSES_WRAP_PREFIX],
2149 [
2150 AC_MSG_CHECKING(for ncurses wrap-prefix)
2151 AC_ARG_WITH(ncurses-wrap-prefix,
2152         [  --with-ncurses-wrap-prefix naming-prefix for ncurses wrapped-variables],
2153         [NCURSES_WRAP_PREFIX=$withval],
2154         [NCURSES_WRAP_PREFIX=_nc_])
2155 AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
2156
2157 AC_SUBST(NCURSES_WRAP_PREFIX)
2158 ])
2159 dnl ---------------------------------------------------------------------------
2160 dnl CF_NETBSD_FORM_H version: 1 updated: 2011/01/15 14:59:18
2161 dnl ----------------
2162 dnl Check for NetBSD's form.h, which is incompatible with SVr4 and ncurses.
2163 dnl Some workarounds are needed in client programs to allow them to compile.
2164 AC_DEFUN([CF_NETBSD_FORM_H],[
2165 AC_CACHE_CHECK(for NetBSD form.h,cf_cv_netbsd_form_h,[
2166 AC_TRY_COMPILE([
2167 #include <${cf_cv_ncurses_header:-curses.h}>
2168 #include <form.h>
2169 ],[
2170         FORM *form;
2171         int y = current_field(form)->cursor_ypos;
2172         int x = current_field(form)->cursor_xpos;
2173 ],[cf_cv_netbsd_form_h=yes
2174 ],[cf_cv_netbsd_form_h=no])
2175 ])
2176
2177 test "$cf_cv_netbsd_form_h" = yes && AC_DEFINE(HAVE_NETBSD_FORM_H)
2178 ])dnl
2179 dnl ---------------------------------------------------------------------------
2180 dnl CF_NETBSD_MENU_H version: 1 updated: 2011/01/15 14:59:18
2181 dnl ----------------
2182 dnl Check for NetBSD's menu.h, which is incompatible with SVr4 and ncurses.
2183 dnl Some workarounds are needed in client programs to allow them to compile.
2184 AC_DEFUN([CF_NETBSD_MENU_H],[
2185 AC_CACHE_CHECK(for NetBSD menu.h,cf_cv_netbsd_menu_h,[
2186 AC_TRY_COMPILE([
2187 #include <${cf_cv_ncurses_header:-curses.h}>
2188 #include <menu.h>
2189 ],[
2190         MENU *menu;
2191         int y = menu->max_item_width;
2192 ],[cf_cv_netbsd_menu_h=yes
2193 ],[cf_cv_netbsd_menu_h=no])
2194 ])
2195
2196 test "$cf_cv_netbsd_menu_h" = yes && AC_DEFINE(HAVE_NETBSD_MENU_H)
2197 ])dnl
2198 dnl ---------------------------------------------------------------------------
2199 dnl CF_NO_LEAKS_OPTION version: 4 updated: 2006/12/16 14:24:05
2200 dnl ------------------
2201 dnl see CF_WITH_NO_LEAKS
2202 AC_DEFUN([CF_NO_LEAKS_OPTION],[
2203 AC_MSG_CHECKING(if you want to use $1 for testing)
2204 AC_ARG_WITH($1,
2205         [$2],
2206         [AC_DEFINE($3)ifelse([$4],,[
2207          $4
2208 ])
2209         : ${with_cflags:=-g}
2210         : ${with_no_leaks:=yes}
2211          with_$1=yes],
2212         [with_$1=])
2213 AC_MSG_RESULT(${with_$1:-no})
2214
2215 case .$with_cflags in #(vi
2216 .*-g*)
2217         case .$CFLAGS in #(vi
2218         .*-g*) #(vi
2219                 ;;
2220         *)
2221                 CF_ADD_CFLAGS([-g])
2222                 ;;
2223         esac
2224         ;;
2225 esac
2226 ])dnl
2227 dnl ---------------------------------------------------------------------------
2228 dnl CF_PATH_SYNTAX version: 13 updated: 2010/05/26 05:38:42
2229 dnl --------------
2230 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2231 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2232 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2233 dnl delayed evaluation of those symbols.
2234 AC_DEFUN([CF_PATH_SYNTAX],[
2235 if test "x$prefix" != xNONE; then
2236   cf_path_syntax="$prefix"
2237 else
2238   cf_path_syntax="$ac_default_prefix"
2239 fi
2240
2241 case ".[$]$1" in #(vi
2242 .\[$]\(*\)*|.\'*\'*) #(vi
2243   ;;
2244 ..|./*|.\\*) #(vi
2245   ;;
2246 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
2247   ;;
2248 .\[$]{*prefix}*) #(vi
2249   eval $1="[$]$1"
2250   case ".[$]$1" in #(vi
2251   .NONE/*)
2252     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2253     ;;
2254   esac
2255   ;; #(vi
2256 .no|.NONE/*)
2257   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2258   ;;
2259 *)
2260   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2261   ;;
2262 esac
2263 ])dnl
2264 dnl ---------------------------------------------------------------------------
2265 dnl CF_PDCURSES_X11 version: 11 updated: 2011/01/15 18:45:38
2266 dnl ---------------
2267 dnl Configure for PDCurses' X11 library
2268 AC_DEFUN([CF_PDCURSES_X11],[
2269 AC_REQUIRE([CF_X_ATHENA])
2270
2271 AC_PATH_PROGS(XCURSES_CONFIG,xcurses-config,none)
2272
2273 if test "$XCURSES_CONFIG" != none ; then
2274
2275 CPPFLAGS="$CPPFLAGS `$XCURSES_CONFIG --cflags`"
2276 CF_ADD_LIBS(`$XCURSES_CONFIG --libs`)
2277
2278 cf_cv_lib_XCurses=yes
2279
2280 else
2281
2282 LDFLAGS="$LDFLAGS $X_LIBS"
2283 CF_CHECK_CFLAGS($X_CFLAGS)
2284 AC_CHECK_LIB(X11,XOpenDisplay,
2285         [CF_ADD_LIBS(-lX11)],,
2286         [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])
2287 AC_CACHE_CHECK(for XCurses library,cf_cv_lib_XCurses,[
2288 CF_ADD_LIBS(-lXCurses)
2289 AC_TRY_LINK([
2290 #include <xcurses.h>
2291 char *XCursesProgramName = "test";
2292 ],[XCursesExit();],
2293 [cf_cv_lib_XCurses=yes],
2294 [cf_cv_lib_XCurses=no])
2295 ])
2296
2297 fi
2298
2299 if test $cf_cv_lib_XCurses = yes ; then
2300         AC_DEFINE(UNIX)
2301         AC_DEFINE(XCURSES)
2302         AC_CHECK_HEADER(xcurses.h, AC_DEFINE(HAVE_XCURSES))
2303 else
2304         AC_MSG_ERROR(Cannot link with XCurses)
2305 fi
2306 ])dnl
2307 dnl ---------------------------------------------------------------------------
2308 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
2309 dnl -------------
2310 dnl Check for the package-config program, unless disabled by command-line.
2311 AC_DEFUN([CF_PKG_CONFIG],
2312 [
2313 AC_MSG_CHECKING(if you want to use pkg-config)
2314 AC_ARG_WITH(pkg-config,
2315         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2316         [cf_pkg_config=$withval],
2317         [cf_pkg_config=yes])
2318 AC_MSG_RESULT($cf_pkg_config)
2319
2320 case $cf_pkg_config in #(vi
2321 no) #(vi
2322         PKG_CONFIG=none
2323         ;;
2324 yes) #(vi
2325         CF_ACVERSION_CHECK(2.52,
2326                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2327                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2328         ;;
2329 *)
2330         PKG_CONFIG=$withval
2331         ;;
2332 esac
2333
2334 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2335 if test "$PKG_CONFIG" != none ; then
2336         CF_PATH_SYNTAX(PKG_CONFIG)
2337 fi
2338
2339 AC_SUBST(PKG_CONFIG)
2340 ])dnl
2341 dnl ---------------------------------------------------------------------------
2342 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
2343 dnl -----------------
2344 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2345 dnl
2346 dnl     POSIX.1-1990                            _POSIX_SOURCE
2347 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2348 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2349 dnl             Bindings Option
2350 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2351 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2352 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2353 dnl
2354 dnl Parameters:
2355 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2356 AC_DEFUN([CF_POSIX_C_SOURCE],
2357 [
2358 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2359
2360 cf_save_CFLAGS="$CFLAGS"
2361 cf_save_CPPFLAGS="$CPPFLAGS"
2362
2363 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2364 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2365
2366 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2367         CF_MSG_LOG(if the symbol is already defined go no further)
2368         AC_TRY_COMPILE([#include <sys/types.h>],[
2369 #ifndef _POSIX_C_SOURCE
2370 make an error
2371 #endif],
2372         [cf_cv_posix_c_source=no],
2373         [cf_want_posix_source=no
2374          case .$cf_POSIX_C_SOURCE in #(vi
2375          .[[12]]??*) #(vi
2376                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2377                 ;;
2378          .2) #(vi
2379                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2380                 cf_want_posix_source=yes
2381                 ;;
2382          .*)
2383                 cf_want_posix_source=yes
2384                 ;;
2385          esac
2386          if test "$cf_want_posix_source" = yes ; then
2387                 AC_TRY_COMPILE([#include <sys/types.h>],[
2388 #ifdef _POSIX_SOURCE
2389 make an error
2390 #endif],[],
2391                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2392          fi
2393          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2394          CFLAGS="$cf_trim_CFLAGS"
2395          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
2396          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2397          AC_TRY_COMPILE([#include <sys/types.h>],[
2398 #ifndef _POSIX_C_SOURCE
2399 make an error
2400 #endif],,
2401          [cf_cv_posix_c_source=no])
2402          CFLAGS="$cf_save_CFLAGS"
2403          CPPFLAGS="$cf_save_CPPFLAGS"
2404         ])
2405 ])
2406
2407 if test "$cf_cv_posix_c_source" != no ; then
2408         CFLAGS="$cf_trim_CFLAGS"
2409         CPPFLAGS="$cf_trim_CPPFLAGS"
2410         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2411 fi
2412
2413 ])dnl
2414 dnl ---------------------------------------------------------------------------
2415 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
2416 dnl ------------
2417 dnl Append definitions and rules for the given programs to the subdirectory
2418 dnl Makefiles, and the recursion rule for the top-level Makefile.
2419 dnl
2420 dnl parameters
2421 dnl     $1 = script to run
2422 dnl     $2 = list of subdirectories
2423 dnl
2424 dnl variables
2425 dnl     $AWK
2426 AC_DEFUN([CF_PRG_RULES],
2427 [
2428 for cf_dir in $2
2429 do
2430         if test ! -d $srcdir/$cf_dir; then
2431                 continue
2432         elif test -f $srcdir/$cf_dir/programs; then
2433                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
2434         fi
2435 done
2436
2437 ])dnl
2438 dnl ---------------------------------------------------------------------------
2439 dnl CF_PROG_CC_U_D version: 1 updated: 2005/07/14 16:59:30
2440 dnl --------------
2441 dnl Check if C (preprocessor) -U and -D options are processed in the order
2442 dnl given rather than by type of option.  Some compilers insist on apply all
2443 dnl of the -U options after all of the -D options.  Others allow mixing them,
2444 dnl and may predefine symbols that conflict with those we define.
2445 AC_DEFUN([CF_PROG_CC_U_D],
2446 [
2447 AC_CACHE_CHECK(if $CC -U and -D options work together,cf_cv_cc_u_d_options,[
2448         cf_save_CPPFLAGS="$CPPFLAGS"
2449         CPPFLAGS="-UU_D_OPTIONS -DU_D_OPTIONS -DD_U_OPTIONS -UD_U_OPTIONS"
2450         AC_TRY_COMPILE([],[
2451 #ifndef U_D_OPTIONS
2452 make an undefined-error
2453 #endif
2454 #ifdef  D_U_OPTIONS
2455 make a defined-error
2456 #endif
2457         ],[
2458         cf_cv_cc_u_d_options=yes],[
2459         cf_cv_cc_u_d_options=no])
2460         CPPFLAGS="$cf_save_CPPFLAGS"
2461 ])
2462 ])dnl
2463 dnl ---------------------------------------------------------------------------
2464 dnl CF_PROG_INSTALL version: 5 updated: 2002/12/21 22:46:07
2465 dnl ---------------
2466 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
2467 dnl misc/tabset install won't work properly.  Usually this happens only when
2468 dnl using the fallback mkinstalldirs script
2469 AC_DEFUN([CF_PROG_INSTALL],
2470 [AC_PROG_INSTALL
2471 case $INSTALL in
2472 /*)
2473   ;;
2474 *)
2475   CF_DIRNAME(cf_dir,$INSTALL)
2476   test -z "$cf_dir" && cf_dir=.
2477   INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
2478   ;;
2479 esac
2480 ])dnl
2481 dnl ---------------------------------------------------------------------------
2482 dnl CF_PROG_LINT version: 2 updated: 2009/08/12 04:43:14
2483 dnl ------------
2484 AC_DEFUN([CF_PROG_LINT],
2485 [
2486 AC_CHECK_PROGS(LINT, tdlint lint alint splint lclint)
2487 AC_SUBST(LINT_OPTS)
2488 ])dnl
2489 dnl ---------------------------------------------------------------------------
2490 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
2491 dnl ----------------
2492 dnl Remove all -U and -D options that refer to the given symbol from a list
2493 dnl of C compiler options.  This works around the problem that not all
2494 dnl compilers process -U and -D options from left-to-right, so a -U option
2495 dnl cannot be used to cancel the effect of a preceding -D option.
2496 dnl
2497 dnl $1 = target (which could be the same as the source variable)
2498 dnl $2 = source (including '$')
2499 dnl $3 = symbol to remove
2500 define([CF_REMOVE_DEFINE],
2501 [
2502 $1=`echo "$2" | \
2503         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
2504                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
2505 ])dnl
2506 dnl ---------------------------------------------------------------------------
2507 dnl CF_SIG_ATOMIC_T version: 2 updated: 2005/09/18 17:27:12
2508 dnl ---------------
2509 dnl signal handler, but there are some gcc depedencies in that recommendation.
2510 dnl Try anyway.
2511 AC_DEFUN([CF_SIG_ATOMIC_T],
2512 [
2513 AC_MSG_CHECKING(for signal global datatype)
2514 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
2515         for cf_type in \
2516                 "volatile sig_atomic_t" \
2517                 "sig_atomic_t" \
2518                 "int"
2519         do
2520         AC_TRY_COMPILE([
2521 #include <sys/types.h>
2522 #include <signal.h>
2523 #include <stdio.h>
2524
2525 extern $cf_type x;
2526 $cf_type x;
2527 static void handler(int sig)
2528 {
2529         x = 5;
2530 }],
2531                 [signal(SIGINT, handler);
2532                  x = 1],
2533                 [cf_cv_sig_atomic_t=$cf_type],
2534                 [cf_cv_sig_atomic_t=no])
2535                 test "$cf_cv_sig_atomic_t" != no && break
2536         done
2537         ])
2538 AC_MSG_RESULT($cf_cv_sig_atomic_t)
2539 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t)
2540 ])dnl
2541 dnl ---------------------------------------------------------------------------
2542 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
2543 dnl --------------
2544 dnl Construct a search-list for a nonstandard header/lib-file
2545 dnl     $1 = the variable to return as result
2546 dnl     $2 = the package name
2547 dnl     $3 = the subdirectory, e.g., bin, include or lib
2548 AC_DEFUN([CF_SUBDIR_PATH],
2549 [
2550 $1=
2551
2552 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
2553 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
2554 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
2555 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
2556 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
2557 ])dnl
2558 dnl ---------------------------------------------------------------------------
2559 dnl CF_SYS_TIME_SELECT version: 4 updated: 2000/10/04 09:18:40
2560 dnl ------------------
2561 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
2562 dnl older SCO configurations.
2563 AC_DEFUN([CF_SYS_TIME_SELECT],
2564 [
2565 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
2566 AC_CACHE_VAL(cf_cv_sys_time_select,[
2567 AC_TRY_COMPILE([
2568 #include <sys/types.h>
2569 #ifdef HAVE_SYS_TIME_H
2570 #include <sys/time.h>
2571 #endif
2572 #ifdef HAVE_SYS_SELECT_H
2573 #include <sys/select.h>
2574 #endif
2575 ],[],[cf_cv_sys_time_select=yes],
2576      [cf_cv_sys_time_select=no])
2577      ])
2578 AC_MSG_RESULT($cf_cv_sys_time_select)
2579 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT)
2580 ])dnl
2581 dnl ---------------------------------------------------------------------------
2582 dnl CF_TERM_HEADER version: 2 updated: 2010/10/23 15:54:49
2583 dnl --------------
2584 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
2585 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
2586 dnl but some packagers change this, breaking various applications.
2587 AC_DEFUN([CF_TERM_HEADER],[
2588 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
2589 case ${cf_cv_ncurses_header} in #(vi
2590 */ncurses.h|*/ncursesw.h) #(vi
2591         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
2592         ;;
2593 *)
2594         cf_term_header=term.h
2595         ;;
2596 esac
2597
2598 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
2599 do
2600 AC_TRY_COMPILE([#include <stdio.h>
2601 #include <${cf_cv_ncurses_header:-curses.h}>
2602 #include <$cf_test>
2603 ],[int x = auto_left_margin],[
2604         cf_cv_term_header="$cf_test"],[
2605         cf_cv_term_header=unknown
2606         ])
2607         test "$cf_cv_term_header" != unknown && break
2608 done
2609 ])
2610
2611 # Set definitions to allow ifdef'ing to accommodate subdirectories
2612
2613 case $cf_cv_term_header in # (vi
2614 *term.h)
2615         AC_DEFINE(HAVE_TERM_H)
2616         ;;
2617 esac
2618
2619 case $cf_cv_term_header in # (vi
2620 ncurses/term.h) #(vi
2621         AC_DEFINE(HAVE_NCURSES_TERM_H)
2622         ;;
2623 ncursesw/term.h)
2624         AC_DEFINE(HAVE_NCURSESW_TERM_H)
2625         ;;
2626 esac
2627 ])dnl
2628 dnl ---------------------------------------------------------------------------
2629 dnl CF_TPUTS_PROTO version: 2 updated: 2011/04/23 19:25:50
2630 dnl --------------
2631 dnl Check for type of function-pointer passed to tputs.  Some old
2632 dnl implementations used functions that had different prototypes, making it
2633 dnl hard to compile portable programs using tputs.
2634 AC_DEFUN([CF_TPUTS_PROTO],[
2635 CF_CURSES_FUNCS(tputs)
2636 if test x$cf_cv_func_tputs = xyes
2637 then
2638         cf_done=no
2639         for cf_arg in int char
2640         do
2641                 for cf_ret in int void
2642                 do
2643                         if test $cf_ret = void
2644                         then
2645                                 cf_return="/* nothing */"
2646                         else
2647                                 cf_return="return value"
2648                         fi
2649                         AC_TRY_COMPILE([
2650 #include <${cf_cv_ncurses_header:-curses.h}>
2651 #include <$cf_cv_term_header>
2652
2653 static $cf_ret outc($cf_arg value) { $cf_return; }
2654 ],[
2655         tputs("hello", 0, outc); 
2656         ${cf_cv_main_return:-return}(0);
2657 ],[
2658                 CF_VERBOSE([prototype $cf_ret func($cf_arg value)])
2659                 cat >>confdefs.h <<EOF
2660 #define TPUTS_ARG               $cf_arg
2661 #define TPUTS_PROTO(func,value) $cf_ret func(TPUTS_ARG value)
2662 #define TPUTS_RETURN(value)     $cf_return
2663 EOF
2664                 cf_done=yes
2665                 break
2666 ])
2667                 done
2668                 test $cf_done = yes && break
2669         done
2670 fi
2671 ])dnl
2672 dnl ---------------------------------------------------------------------------
2673 dnl CF_TRY_PKG_CONFIG version: 4 updated: 2010/06/14 17:42:30
2674 dnl -----------------
2675 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
2676 dnl available in that form.
2677 dnl
2678 dnl $1 = package name
2679 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
2680 dnl $3 = logic to use if pkg-config does not have the package
2681 AC_DEFUN([CF_TRY_PKG_CONFIG],[
2682 AC_REQUIRE([CF_PKG_CONFIG])
2683
2684 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists $1; then
2685         CF_VERBOSE(found package $1)
2686         cf_pkgconfig_incs="`$PKG_CONFIG --cflags $1 2>/dev/null`"
2687         cf_pkgconfig_libs="`$PKG_CONFIG --libs   $1 2>/dev/null`"
2688         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
2689         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
2690         CF_ADD_CFLAGS($cf_pkgconfig_incs)
2691         CF_ADD_LIBS($cf_pkgconfig_libs)
2692         ifelse([$2],,:,[$2])
2693 else
2694         ifelse([$3],,:,[$3])
2695 fi
2696 ])
2697 dnl ---------------------------------------------------------------------------
2698 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
2699 dnl --------
2700 dnl Make an uppercase version of a variable
2701 dnl $1=uppercase($2)
2702 AC_DEFUN([CF_UPPER],
2703 [
2704 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
2705 ])dnl
2706 dnl ---------------------------------------------------------------------------
2707 dnl CF_UTF8_LIB version: 7 updated: 2010/06/20 09:24:28
2708 dnl -----------
2709 dnl Check for multibyte support, and if not found, utf8 compatibility library
2710 AC_DEFUN([CF_UTF8_LIB],
2711 [
2712 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
2713         cf_save_LIBS="$LIBS"
2714         AC_TRY_LINK([
2715 #include <stdlib.h>],[putwc(0,0);],
2716         [cf_cv_utf8_lib=yes],
2717         [CF_FIND_LINKAGE([
2718 #include <libutf8.h>],[putwc(0,0);],utf8,
2719                 [cf_cv_utf8_lib=add-on],
2720                 [cf_cv_utf8_lib=no])
2721 ])])
2722
2723 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
2724 # ncurses/ncursesw:
2725 if test "$cf_cv_utf8_lib" = "add-on" ; then
2726         AC_DEFINE(HAVE_LIBUTF8_H)
2727         CF_ADD_INCDIR($cf_cv_header_path_utf8)
2728         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
2729         CF_ADD_LIBS($cf_cv_library_file_utf8)
2730 fi
2731 ])dnl
2732 dnl ---------------------------------------------------------------------------
2733 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
2734 dnl ----------
2735 dnl Use AC_VERBOSE w/o the warnings
2736 AC_DEFUN([CF_VERBOSE],
2737 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
2738 CF_MSG_LOG([$1])
2739 ])dnl
2740 dnl ---------------------------------------------------------------------------
2741 dnl CF_WCHAR_TYPE version: 3 updated: 2010/05/26 16:44:57
2742 dnl -------------
2743 dnl Check if type wide-character type $1 is declared, and if so, which header
2744 dnl file is needed.  The second parameter is used to set a shell variable when
2745 dnl the type is not found.  The first parameter sets a shell variable for the
2746 dnl opposite sense.
2747 AC_DEFUN([CF_WCHAR_TYPE],
2748 [
2749 # This is needed on Tru64 5.0 to declare $1
2750 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
2751 AC_TRY_COMPILE([
2752 #include <stdlib.h>
2753 #include <stdarg.h>
2754 #include <stdio.h>
2755 #ifdef HAVE_LIBUTF8_H
2756 #include <libutf8.h>
2757 #endif],
2758         [$1 state],
2759         [cf_cv_$1=no],
2760         [AC_TRY_COMPILE([
2761 #include <stdlib.h>
2762 #include <stdarg.h>
2763 #include <stdio.h>
2764 #include <wchar.h>
2765 #ifdef HAVE_LIBUTF8_H
2766 #include <libutf8.h>
2767 #endif],
2768         [$1 value],
2769         [cf_cv_$1=yes],
2770         [cf_cv_$1=unknown])])])
2771
2772 if test "$cf_cv_$1" = yes ; then
2773         AC_DEFINE(NEED_WCHAR_H)
2774         NEED_WCHAR_H=1
2775 fi
2776
2777 ifelse([$2],,,[
2778 # if we do not find $1 in either place, use substitution to provide a fallback.
2779 if test "$cf_cv_$1" = unknown ; then
2780         $2=1
2781 fi
2782 ])
2783 ifelse($3,,,[
2784 # if we find $1 in either place, use substitution to provide a fallback.
2785 if test "$cf_cv_$1" != unknown ; then
2786         $3=1
2787 fi
2788 ])
2789 ])dnl
2790 dnl ---------------------------------------------------------------------------
2791 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
2792 dnl ------------------
2793 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
2794 dnl libraries.
2795 AC_DEFUN([CF_WITH_CURSES_DIR],[
2796
2797 AC_MSG_CHECKING(for specific curses-directory)
2798 AC_ARG_WITH(curses-dir,
2799         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
2800         [cf_cv_curses_dir=$withval],
2801         [cf_cv_curses_dir=no])
2802 AC_MSG_RESULT($cf_cv_curses_dir)
2803
2804 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2805 then
2806         CF_PATH_SYNTAX(withval)
2807         if test -d "$cf_cv_curses_dir"
2808         then
2809                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
2810                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
2811         fi
2812 fi
2813 ])dnl
2814 dnl ---------------------------------------------------------------------------
2815 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
2816 dnl ----------------
2817 dnl Configure-option for dbmalloc.  The optional parameter is used to override
2818 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
2819 AC_DEFUN([CF_WITH_DBMALLOC],[
2820 CF_NO_LEAKS_OPTION(dbmalloc,
2821         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
2822         [USE_DBMALLOC])
2823
2824 if test "$with_dbmalloc" = yes ; then
2825         AC_CHECK_HEADER(dbmalloc.h,
2826                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
2827 fi
2828 ])dnl
2829 dnl ---------------------------------------------------------------------------
2830 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
2831 dnl ---------------
2832 dnl Configure-option for dmalloc.  The optional parameter is used to override
2833 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
2834 AC_DEFUN([CF_WITH_DMALLOC],[
2835 CF_NO_LEAKS_OPTION(dmalloc,
2836         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
2837         [USE_DMALLOC])
2838
2839 if test "$with_dmalloc" = yes ; then
2840         AC_CHECK_HEADER(dmalloc.h,
2841                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
2842 fi
2843 ])dnl
2844 dnl ---------------------------------------------------------------------------
2845 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
2846 dnl ----------------
2847 AC_DEFUN([CF_WITH_VALGRIND],[
2848 CF_NO_LEAKS_OPTION(valgrind,
2849         [  --with-valgrind         test: use valgrind],
2850         [USE_VALGRIND])
2851 ])dnl
2852 dnl ---------------------------------------------------------------------------
2853 dnl CF_XOPEN_CURSES version: 11 updated: 2011/01/18 18:15:30
2854 dnl ---------------
2855 dnl Test if we should define X/Open source for curses, needed on Digital Unix
2856 dnl 4.x, to see the extended functions, but breaks on IRIX 6.x.
2857 dnl
2858 dnl The getbegyx() check is needed for HPUX, which omits legacy macros such
2859 dnl as getbegy().  The latter is better design, but the former is standard.
2860 AC_DEFUN([CF_XOPEN_CURSES],
2861 [
2862 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2863 AC_CACHE_CHECK(if we must define _XOPEN_SOURCE_EXTENDED,cf_cv_need_xopen_extension,[
2864 AC_TRY_LINK([
2865 #include <stdlib.h>
2866 #include <${cf_cv_ncurses_header:-curses.h}>],[
2867 #if defined(NCURSES_VERSION_PATCH)
2868 #if (NCURSES_VERSION_PATCH < 20100501) && (NCURSES_VERSION_PATCH >= 20100403)
2869         make an error
2870 #endif
2871 #endif
2872         long x = winnstr(stdscr, "", 0);
2873         int x1, y1;
2874         getbegyx(stdscr, y1, x1)],
2875         [cf_cv_need_xopen_extension=no],
2876         [AC_TRY_LINK([
2877 #define _XOPEN_SOURCE_EXTENDED
2878 #include <stdlib.h>
2879 #include <${cf_cv_ncurses_header:-curses.h}>],[
2880 #ifdef NCURSES_VERSION
2881         cchar_t check;
2882         int check2 = curs_set((int)sizeof(check));
2883 #endif
2884         long x = winnstr(stdscr, "", 0);
2885         int x1, y1;
2886         getbegyx(stdscr, y1, x1)],
2887         [cf_cv_need_xopen_extension=yes],
2888         [cf_cv_need_xopen_extension=unknown])])])
2889 test $cf_cv_need_xopen_extension = yes && CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED"
2890 ])dnl
2891 dnl ---------------------------------------------------------------------------
2892 dnl CF_XOPEN_SOURCE version: 35 updated: 2011/02/20 20:37:37
2893 dnl ---------------
2894 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
2895 dnl or adapt to the vendor's definitions to get equivalent functionality,
2896 dnl without losing the common non-POSIX features.
2897 dnl
2898 dnl Parameters:
2899 dnl     $1 is the nominal value for _XOPEN_SOURCE
2900 dnl     $2 is the nominal value for _POSIX_C_SOURCE
2901 AC_DEFUN([CF_XOPEN_SOURCE],[
2902
2903 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
2904 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
2905 cf_xopen_source=
2906
2907 case $host_os in #(vi
2908 aix[[456]]*) #(vi
2909         cf_xopen_source="-D_ALL_SOURCE"
2910         ;;
2911 cygwin) #(vi
2912         cf_XOPEN_SOURCE=600
2913         ;;
2914 darwin[[0-8]].*) #(vi
2915         cf_xopen_source="-D_APPLE_C_SOURCE"
2916         ;;
2917 darwin*) #(vi
2918         cf_xopen_source="-D_DARWIN_C_SOURCE"
2919         ;;
2920 freebsd*|dragonfly*) #(vi
2921         # 5.x headers associate
2922         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
2923         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
2924         cf_POSIX_C_SOURCE=200112L
2925         cf_XOPEN_SOURCE=600
2926         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
2927         ;;
2928 hpux11*) #(vi
2929         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
2930         ;;
2931 hpux*) #(vi
2932         cf_xopen_source="-D_HPUX_SOURCE"
2933         ;;
2934 irix[[56]].*) #(vi
2935         cf_xopen_source="-D_SGI_SOURCE"
2936         ;;
2937 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
2938         CF_GNU_SOURCE
2939         ;;
2940 mirbsd*) #(vi
2941         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <arpa/inet.h>
2942         ;;
2943 netbsd*) #(vi
2944         # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
2945         ;;
2946 openbsd*) #(vi
2947         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
2948         ;;
2949 osf[[45]]*) #(vi
2950         cf_xopen_source="-D_OSF_SOURCE"
2951         ;;
2952 nto-qnx*) #(vi
2953         cf_xopen_source="-D_QNX_SOURCE"
2954         ;;
2955 sco*) #(vi
2956         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
2957         ;;
2958 solaris2.1[[0-9]]) #(vi
2959         cf_xopen_source="-D__EXTENSIONS__ -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
2960         ;;
2961 solaris2.[[1-9]]) #(vi
2962         cf_xopen_source="-D__EXTENSIONS__"
2963         ;;
2964 *)
2965         AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
2966         AC_TRY_COMPILE([#include <sys/types.h>],[
2967 #ifndef _XOPEN_SOURCE
2968 make an error
2969 #endif],
2970         [cf_cv_xopen_source=no],
2971         [cf_save="$CPPFLAGS"
2972          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
2973          AC_TRY_COMPILE([#include <sys/types.h>],[
2974 #ifdef _XOPEN_SOURCE
2975 make an error
2976 #endif],
2977         [cf_cv_xopen_source=no],
2978         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
2979         CPPFLAGS="$cf_save"
2980         ])
2981 ])
2982         if test "$cf_cv_xopen_source" != no ; then
2983                 CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
2984                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
2985                 cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
2986                 CF_ADD_CFLAGS($cf_temp_xopen_source)
2987         fi
2988         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
2989         ;;
2990 esac
2991
2992 if test -n "$cf_xopen_source" ; then
2993         CF_ADD_CFLAGS($cf_xopen_source)
2994 fi
2995 ])
2996 dnl ---------------------------------------------------------------------------
2997 dnl CF_X_ATHENA version: 20 updated: 2010/11/09 05:18:02
2998 dnl -----------
2999 dnl Check for Xaw (Athena) libraries
3000 dnl
3001 dnl Sets $cf_x_athena according to the flavor of Xaw which is used.
3002 AC_DEFUN([CF_X_ATHENA],
3003 [
3004 cf_x_athena=${cf_x_athena:-Xaw}
3005
3006 AC_MSG_CHECKING(if you want to link with Xaw 3d library)
3007 withval=
3008 AC_ARG_WITH(Xaw3d,
3009         [  --with-Xaw3d            link with Xaw 3d library])
3010 if test "$withval" = yes ; then
3011         cf_x_athena=Xaw3d
3012         AC_MSG_RESULT(yes)
3013 else
3014         AC_MSG_RESULT(no)
3015 fi
3016
3017 AC_MSG_CHECKING(if you want to link with neXT Athena library)
3018 withval=
3019 AC_ARG_WITH(neXtaw,
3020         [  --with-neXtaw           link with neXT Athena library])
3021 if test "$withval" = yes ; then
3022         cf_x_athena=neXtaw
3023         AC_MSG_RESULT(yes)
3024 else
3025         AC_MSG_RESULT(no)
3026 fi
3027
3028 AC_MSG_CHECKING(if you want to link with Athena-Plus library)
3029 withval=
3030 AC_ARG_WITH(XawPlus,
3031         [  --with-XawPlus          link with Athena-Plus library])
3032 if test "$withval" = yes ; then
3033         cf_x_athena=XawPlus
3034         AC_MSG_RESULT(yes)
3035 else
3036         AC_MSG_RESULT(no)
3037 fi
3038
3039 cf_x_athena_lib=""
3040
3041 if test "$PKG_CONFIG" != none ; then
3042         cf_athena_list=
3043         test "$cf_x_athena" = Xaw && cf_athena_list="xaw8 xaw7 xaw6"
3044         for cf_athena_pkg in \
3045                 $cf_athena_list \
3046                 ${cf_x_athena} \
3047                 ${cf_x_athena}-devel \
3048                 lib${cf_x_athena} \
3049                 lib${cf_x_athena}-devel
3050         do
3051                 CF_TRY_PKG_CONFIG($cf_athena_pkg,[
3052                         cf_x_athena_lib="$cf_pkgconfig_libs"
3053                         CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
3054                         AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
3055
3056 AC_CACHE_CHECK(for usable $cf_x_athena/Xmu package,cf_cv_xaw_compat,[
3057 AC_TRY_LINK([
3058 #include <X11/Xmu/CharSet.h>
3059 ],[
3060 int check = XmuCompareISOLatin1("big", "small")
3061 ],[cf_cv_xaw_compat=yes],[cf_cv_xaw_compat=no])])
3062
3063                         if test "$cf_cv_xaw_compat" = no
3064                         then
3065                                 # workaround for broken ".pc" files...
3066                                 case "$cf_x_athena_lib" in #(vi
3067                                 *-lXmu*) #(vi
3068                                         ;;
3069                                 *)
3070                                         CF_VERBOSE(work around broken package)
3071                                         CF_TRY_PKG_CONFIG(xmu,,[CF_ADD_LIB_AFTER(-lXt,-lXmu)])
3072                                         ;;
3073                                 esac
3074                         fi
3075
3076                         break])
3077         done
3078 fi
3079
3080 if test -z "$cf_x_athena_lib" ; then
3081         CF_X_EXT
3082         CF_X_TOOLKIT
3083         CF_X_ATHENA_CPPFLAGS($cf_x_athena)
3084         CF_X_ATHENA_LIBS($cf_x_athena)
3085 fi
3086 ])dnl
3087 dnl ---------------------------------------------------------------------------
3088 dnl CF_X_ATHENA_CPPFLAGS version: 5 updated: 2010/05/26 17:35:30
3089 dnl --------------------
3090 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
3091 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
3092 AC_DEFUN([CF_X_ATHENA_CPPFLAGS],
3093 [
3094 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
3095 cf_x_athena_inc=""
3096
3097 for cf_path in default \
3098         /usr/contrib/X11R6 \
3099         /usr/contrib/X11R5 \
3100         /usr/lib/X11R5 \
3101         /usr/local
3102 do
3103         if test -z "$cf_x_athena_inc" ; then
3104                 cf_save="$CPPFLAGS"
3105                 cf_test=X11/$cf_x_athena_root/SimpleMenu.h
3106                 if test $cf_path != default ; then
3107                         CPPFLAGS="$cf_save -I$cf_path/include"
3108                         AC_MSG_CHECKING(for $cf_test in $cf_path)
3109                 else
3110                         AC_MSG_CHECKING(for $cf_test)
3111                 fi
3112                 AC_TRY_COMPILE([
3113 #include <X11/Intrinsic.h>
3114 #include <$cf_test>],[],
3115                         [cf_result=yes],
3116                         [cf_result=no])
3117                 AC_MSG_RESULT($cf_result)
3118                 if test "$cf_result" = yes ; then
3119                         cf_x_athena_inc=$cf_path
3120                         break
3121                 else
3122                         CPPFLAGS="$cf_save"
3123                 fi
3124         fi
3125 done
3126
3127 if test -z "$cf_x_athena_inc" ; then
3128         AC_MSG_WARN(
3129 [Unable to successfully find Athena header files with test program])
3130 elif test "$cf_x_athena_inc" != default ; then
3131         CPPFLAGS="$CPPFLAGS -I$cf_x_athena_inc"
3132 fi
3133 ])
3134 dnl ---------------------------------------------------------------------------
3135 dnl CF_X_ATHENA_LIBS version: 10 updated: 2011/02/13 13:31:33
3136 dnl ----------------
3137 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
3138 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
3139 AC_DEFUN([CF_X_ATHENA_LIBS],
3140 [AC_REQUIRE([CF_X_TOOLKIT])
3141 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
3142 cf_x_athena_lib=""
3143
3144 for cf_path in default \
3145         /usr/contrib/X11R6 \
3146         /usr/contrib/X11R5 \
3147         /usr/lib/X11R5 \
3148         /usr/local
3149 do
3150         for cf_lib in \
3151                 "-l$cf_x_athena_root -lXmu" \
3152                 "-l$cf_x_athena_root -lXpm -lXmu" \
3153                 "-l${cf_x_athena_root}_s -lXmu_s"
3154         do
3155                 if test -z "$cf_x_athena_lib" ; then
3156                         cf_save="$LIBS"
3157                         cf_test=XawSimpleMenuAddGlobalActions
3158                         if test $cf_path != default ; then
3159                                 CF_ADD_LIBS(-L$cf_path/lib $cf_lib)
3160                                 AC_MSG_CHECKING(for $cf_lib in $cf_path)
3161                         else
3162                                 CF_ADD_LIBS($cf_lib)
3163                                 AC_MSG_CHECKING(for $cf_test in $cf_lib)
3164                         fi
3165                         AC_TRY_LINK([
3166 #include <X11/Intrinsic.h>
3167 #include <X11/$cf_x_athena_root/SimpleMenu.h>
3168 ],[
3169 $cf_test((XtAppContext) 0)],
3170                                 [cf_result=yes],
3171                                 [cf_result=no])
3172                         AC_MSG_RESULT($cf_result)
3173                         if test "$cf_result" = yes ; then
3174                                 cf_x_athena_lib="$cf_lib"
3175                                 break
3176                         fi
3177                         LIBS="$cf_save"
3178                 fi
3179         done
3180 done
3181
3182 if test -z "$cf_x_athena_lib" ; then
3183         AC_MSG_ERROR(
3184 [Unable to successfully link Athena library (-l$cf_x_athena_root) with test program])
3185 fi
3186
3187 CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
3188 AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
3189 ])
3190 dnl ---------------------------------------------------------------------------
3191 dnl CF_X_EXT version: 3 updated: 2010/06/02 05:03:05
3192 dnl --------
3193 AC_DEFUN([CF_X_EXT],[
3194 CF_TRY_PKG_CONFIG(Xext,,[
3195         AC_CHECK_LIB(Xext,XextCreateExtension,
3196                 [CF_ADD_LIB(Xext)])])
3197 ])dnl
3198 dnl ---------------------------------------------------------------------------
3199 dnl CF_X_TOOLKIT version: 20 updated: 2010/11/19 05:43:04
3200 dnl ------------
3201 dnl Check for X Toolkit libraries
3202 dnl
3203 AC_DEFUN([CF_X_TOOLKIT],
3204 [
3205 AC_REQUIRE([AC_PATH_XTRA])
3206 AC_REQUIRE([CF_CHECK_CACHE])
3207
3208 cf_have_X_LIBS=no
3209
3210 CF_TRY_PKG_CONFIG(xt,[
3211
3212         case "x$LIBS" in #(vi
3213         *-lX11*) #(vi
3214                 ;;
3215         *)
3216 # we have an "xt" package, but it may omit Xt's dependency on X11
3217 AC_CACHE_CHECK(for usable X dependency,cf_cv_xt_x11_compat,[
3218 AC_TRY_LINK([
3219 #include <X11/Xlib.h>
3220 ],[
3221         int rc1 = XDrawLine((Display*) 0, (Drawable) 0, (GC) 0, 0, 0, 0, 0);
3222         int rc2 = XClearWindow((Display*) 0, (Window) 0);
3223         int rc3 = XMoveWindow((Display*) 0, (Window) 0, 0, 0);
3224         int rc4 = XMoveResizeWindow((Display*)0, (Window)0, 0, 0, 0, 0);
3225 ],[cf_cv_xt_x11_compat=yes],[cf_cv_xt_x11_compat=no])])
3226                 if test "$cf_cv_xt_x11_compat" = no
3227                 then
3228                         CF_VERBOSE(work around broken X11 dependency)
3229                         # 2010/11/19 - good enough until a working Xt on Xcb is delivered.
3230                         CF_TRY_PKG_CONFIG(x11,,[CF_ADD_LIB_AFTER(-lXt,-lX11)])
3231                 fi
3232                 ;;
3233         esac
3234
3235 AC_CACHE_CHECK(for usable X Toolkit package,cf_cv_xt_ice_compat,[
3236 AC_TRY_LINK([
3237 #include <X11/Shell.h>
3238 ],[int num = IceConnectionNumber(0)
3239 ],[cf_cv_xt_ice_compat=yes],[cf_cv_xt_ice_compat=no])])
3240
3241         if test "$cf_cv_xt_ice_compat" = no
3242         then
3243                 # workaround for broken ".pc" files used for X Toolkit.
3244                 case "x$X_PRE_LIBS" in #(vi
3245                 *-lICE*)
3246                         case "x$LIBS" in #(vi
3247                         *-lICE*) #(vi
3248                                 ;;
3249                         *)
3250                                 CF_VERBOSE(work around broken ICE dependency)
3251                                 CF_TRY_PKG_CONFIG(ice,
3252                                         [CF_TRY_PKG_CONFIG(sm)],
3253                                         [CF_ADD_LIB_AFTER(-lXt,$X_PRE_LIBS)])
3254                                 ;;
3255                         esac
3256                         ;;
3257                 esac
3258         fi
3259
3260         cf_have_X_LIBS=yes
3261 ],[
3262
3263         LDFLAGS="$X_LIBS $LDFLAGS"
3264         CF_CHECK_CFLAGS($X_CFLAGS)
3265
3266         AC_CHECK_FUNC(XOpenDisplay,,[
3267         AC_CHECK_LIB(X11,XOpenDisplay,
3268                 [CF_ADD_LIB(X11)],,
3269                 [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])])
3270
3271         AC_CHECK_FUNC(XtAppInitialize,,[
3272         AC_CHECK_LIB(Xt, XtAppInitialize,
3273                 [AC_DEFINE(HAVE_LIBXT)
3274                  cf_have_X_LIBS=Xt
3275                  LIBS="-lXt $X_PRE_LIBS $LIBS $X_EXTRA_LIBS"],,
3276                 [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])])
3277 ])
3278
3279 if test $cf_have_X_LIBS = no ; then
3280         AC_MSG_WARN(
3281 [Unable to successfully link X Toolkit library (-lXt) with
3282 test program.  You will have to check and add the proper libraries by hand
3283 to makefile.])
3284 fi
3285 ])dnl
3286 dnl ---------------------------------------------------------------------------
3287 dnl CF__CURSES_HEAD version: 2 updated: 2010/10/23 15:54:49
3288 dnl ---------------
3289 dnl Define a reusable chunk which includes <curses.h> and <term.h> when they
3290 dnl are both available.
3291 define([CF__CURSES_HEAD],[
3292 #ifdef HAVE_XCURSES
3293 #include <xcurses.h>
3294 char * XCursesProgramName = "test";
3295 #else
3296 #include <${cf_cv_ncurses_header:-curses.h}>
3297 #if defined(NCURSES_VERSION) && defined(HAVE_NCURSESW_TERM_H)
3298 #include <ncursesw/term.h>
3299 #elif defined(NCURSES_VERSION) && defined(HAVE_NCURSES_TERM_H)
3300 #include <ncurses/term.h>
3301 #elif defined(HAVE_TERM_H)
3302 #include <term.h>
3303 #endif
3304 #endif
3305 ])