test/aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 2003-2010,2011 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl $Id: aclocal.m4,v 1.73 2011/12/11 00:06:02 tom Exp $
  30 dnl
  31 dnl Author: Thomas E. Dickey
  32 dnl
  33 dnl Macros used in NCURSES test programs auto-configuration script.
  34 dnl
  35 dnl These macros are maintained separately from NCURSES.  The copyright on
  36 dnl this file applies to the aggregation of macros and does not affect use of
  37 dnl these macros in other applications.
  38 dnl
  39 dnl See http://invisible-island.net/autoconf/ for additional information.
  40 dnl
  41 dnl ---------------------------------------------------------------------------
  42 dnl ---------------------------------------------------------------------------
  43 dnl CF_ACVERSION_CHECK version: 2 updated: 2011/05/08 11:22:03
  44 dnl ------------------
  45 dnl Conditionally generate script according to whether we're using a given autoconf.
  46 dnl
  47 dnl $1 = version to compare against
  48 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  49 dnl $3 = code to use if AC_ACVERSION is older than $1.
  50 define(CF_ACVERSION_CHECK,
  51 [
  52 ifdef([m4_version_compare],
  53 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  54 [CF_ACVERSION_COMPARE(
  55 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  56 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  57 dnl ---------------------------------------------------------------------------
  58 dnl CF_ACVERSION_COMPARE version: 2 updated: 2011/04/14 20:56:50
  59 dnl --------------------
  60 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  61 dnl                      MAJOR2, MINOR2, TERNARY2,
  62 dnl                      PRINTABLE2, not FOUND, FOUND)
  63 define(CF_ACVERSION_COMPARE,
  64 [ifelse(builtin([eval], [$2 < $5]), 1,
  65 [ifelse([$8], , ,[$8])],
  66 [ifelse([$9], , ,[$9])])])dnl
  67 dnl ---------------------------------------------------------------------------
  68 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
  69 dnl -------------
  70 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
  71 dnl The second parameter if given makes this macro verbose.
  72 dnl
  73 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
  74 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
  75 dnl confused by the quotes (which require backslashes to keep them usable).
  76 AC_DEFUN([CF_ADD_CFLAGS],
  77 [
  78 cf_fix_cppflags=no
  79 cf_new_cflags=
  80 cf_new_cppflags=
  81 cf_new_extra_cppflags=
  82
  83 for cf_add_cflags in $1
  84 do
  85 case $cf_fix_cppflags in
  86 no)
  87         case $cf_add_cflags in #(vi
  88         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
  89                 case $cf_add_cflags in
  90                 -D*)
  91                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
  92
  93                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
  94                                 && test -z "${cf_tst_cflags}" \
  95                                 && cf_fix_cppflags=yes
  96
  97                         if test $cf_fix_cppflags = yes ; then
  98                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
  99                                 continue
 100                         elif test "${cf_tst_cflags}" = "\"'" ; then
 101                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 102                                 continue
 103                         fi
 104                         ;;
 105                 esac
 106                 case "$CPPFLAGS" in
 107                 *$cf_add_cflags) #(vi
 108                         ;;
 109                 *) #(vi
 110                         case $cf_add_cflags in #(vi
 111                         -D*)
 112                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 113                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 114                                 ;;
 115                         esac
 116                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 117                         ;;
 118                 esac
 119                 ;;
 120         *)
 121                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 122                 ;;
 123         esac
 124         ;;
 125 yes)
 126         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 127
 128         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 129
 130         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 131                 && test -z "${cf_tst_cflags}" \
 132                 && cf_fix_cppflags=no
 133         ;;
 134 esac
 135 done
 136
 137 if test -n "$cf_new_cflags" ; then
 138         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 139         CFLAGS="$CFLAGS $cf_new_cflags"
 140 fi
 141
 142 if test -n "$cf_new_cppflags" ; then
 143         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 144         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 145 fi
 146
 147 if test -n "$cf_new_extra_cppflags" ; then
 148         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 149         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 150 fi
 151
 152 AC_SUBST(EXTRA_CPPFLAGS)
 153
 154 ])dnl
 155 dnl ---------------------------------------------------------------------------
 156 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 157 dnl -------------
 158 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 159 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 160 dnl but old versions (and some misinstalled ones) need that.  To make things
 161 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 162 dnl the include-path).
 163 AC_DEFUN([CF_ADD_INCDIR],
 164 [
 165 if test -n "$1" ; then
 166   for cf_add_incdir in $1
 167   do
 168         while test $cf_add_incdir != /usr/include
 169         do
 170           if test -d $cf_add_incdir
 171           then
 172                 cf_have_incdir=no
 173                 if test -n "$CFLAGS$CPPFLAGS" ; then
 174                   # a loop is needed to ensure we can add subdirs of existing dirs
 175                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 176                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 177                           cf_have_incdir=yes; break
 178                         fi
 179                   done
 180                 fi
 181
 182                 if test "$cf_have_incdir" = no ; then
 183                   if test "$cf_add_incdir" = /usr/local/include ; then
 184                         if test "$GCC" = yes
 185                         then
 186                           cf_save_CPPFLAGS=$CPPFLAGS
 187                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 188                           AC_TRY_COMPILE([#include <stdio.h>],
 189                                   [printf("Hello")],
 190                                   [],
 191                                   [cf_have_incdir=yes])
 192                           CPPFLAGS=$cf_save_CPPFLAGS
 193                         fi
 194                   fi
 195                 fi
 196
 197                 if test "$cf_have_incdir" = no ; then
 198                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 199                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 200
 201                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 202                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 203                   cf_add_incdir="$cf_top_incdir"
 204                 else
 205                   break
 206                 fi
 207           fi
 208         done
 209   done
 210 fi
 211 ])dnl
 212 dnl ---------------------------------------------------------------------------
 213 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 214 dnl ----------
 215 dnl Add a library, used to enforce consistency.
 216 dnl
 217 dnl $1 = library to add, without the "-l"
 218 dnl $2 = variable to update (default $LIBS)
 219 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 220 dnl ---------------------------------------------------------------------------
 221 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 222 dnl -------------
 223 dnl     Adds to the library-path
 224 dnl
 225 dnl     Some machines have trouble with multiple -L options.
 226 dnl
 227 dnl $1 is the (list of) directory(s) to add
 228 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 229 dnl
 230 AC_DEFUN([CF_ADD_LIBDIR],
 231 [
 232 if test -n "$1" ; then
 233   for cf_add_libdir in $1
 234   do
 235     if test $cf_add_libdir = /usr/lib ; then
 236       :
 237     elif test -d $cf_add_libdir
 238     then
 239       cf_have_libdir=no
 240       if test -n "$LDFLAGS$LIBS" ; then
 241         # a loop is needed to ensure we can add subdirs of existing dirs
 242         for cf_test_libdir in $LDFLAGS $LIBS ; do
 243           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 244             cf_have_libdir=yes; break
 245           fi
 246         done
 247       fi
 248       if test "$cf_have_libdir" = no ; then
 249         CF_VERBOSE(adding $cf_add_libdir to library-path)
 250         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 251       fi
 252     fi
 253   done
 254 fi
 255 ])dnl
 256 dnl ---------------------------------------------------------------------------
 257 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 258 dnl -----------
 259 dnl Add one or more libraries, used to enforce consistency.
 260 dnl
 261 dnl $1 = libraries to add, with the "-l", etc.
 262 dnl $2 = variable to update (default $LIBS)
 263 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 264 dnl ---------------------------------------------------------------------------
 265 dnl CF_ADD_LIB_AFTER version: 2 updated: 2010/11/08 20:33:46
 266 dnl ----------------
 267 dnl Add a given library after another, e.g., following the one it satisfies a
 268 dnl dependency for.
 269 dnl
 270 dnl $1 = the first library
 271 dnl $2 = its dependency
 272 AC_DEFUN([CF_ADD_LIB_AFTER],[
 273 CF_VERBOSE(...before $LIBS)
 274 LIBS=`echo "$LIBS" | sed -e "s/[[       ]][[    ]]*/ /g" -e "s,$1 ,$1 $2 ," -e 's/  / /g'`
 275 CF_VERBOSE(...after  $LIBS)
 276 ])dnl
 277 dnl ---------------------------------------------------------------------------
 278 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
 279 dnl ------------------
 280 dnl Append to a search-list for a nonstandard header/lib-file
 281 dnl     $1 = the variable to return as result
 282 dnl     $2 = the package name
 283 dnl     $3 = the subdirectory, e.g., bin, include or lib
 284 dnl $4 = the directory under which we will test for subdirectories
 285 dnl $5 = a directory that we do not want $4 to match
 286 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 287 [
 288 test "$4" != "$5" && \
 289 test -d "$4" && \
 290 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
 291         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 292         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 293         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 294         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 295         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 296         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 297 }
 298 ])dnl
 299 dnl ---------------------------------------------------------------------------
 300 dnl CF_ANSI_CC_CHECK version: 11 updated: 2011/07/01 19:47:45
 301 dnl ----------------
 302 dnl This was originally adapted from the macros 'fp_PROG_CC_STDC' and
 303 dnl 'fp_C_PROTOTYPES' in the sharutils 4.2 distribution.
 304 AC_DEFUN([CF_ANSI_CC_CHECK],
 305 [
 306 # This should have been defined by AC_PROG_CC
 307 : ${CC:=cc}
 308
 309 # Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 310 # into CC.  This will not help with broken scripts that wrap the compiler with
 311 # options, but eliminates a more common category of user confusion.
 312 AC_MSG_CHECKING(\$CC variable)
 313 case "$CC" in #(vi
 314 *[[\ \  ]]-[[IUD]]*)
 315         AC_MSG_RESULT(broken)
 316         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 317         # humor him...
 318         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 319         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 320         CF_ADD_CFLAGS($cf_flags)
 321         ;;
 322 *)
 323         AC_MSG_RESULT(ok)
 324         ;;
 325 esac
 326
 327 AC_CACHE_CHECK(for ${CC:-cc} option to accept ANSI C, cf_cv_ansi_cc,[
 328 cf_cv_ansi_cc=no
 329 cf_save_CFLAGS="$CFLAGS"
 330 cf_save_CPPFLAGS="$CPPFLAGS"
 331 # Don't try gcc -ansi; that turns off useful extensions and
 332 # breaks some systems' header files.
 333 # AIX                   -qlanglvl=ansi
 334 # Ultrix and OSF/1      -std1
 335 # HP-UX                 -Aa -D_HPUX_SOURCE
 336 # SVR4                  -Xc
 337 # UnixWare 1.2          (cannot use -Xc, since ANSI/POSIX clashes)
 338 for cf_arg in "-DCC_HAS_PROTOS" \
 339         "" \
 340         -qlanglvl=ansi \
 341         -std1 \
 342         -Ae \
 343         "-Aa -D_HPUX_SOURCE" \
 344         -Xc
 345 do
 346         CF_ADD_CFLAGS($cf_arg)
 347         AC_TRY_COMPILE(
 348 [
 349 #ifndef CC_HAS_PROTOS
 350 #if !defined(__STDC__) || (__STDC__ != 1)
 351 choke me
 352 #endif
 353 #endif
 354 ],[
 355         int test (int i, double x);
 356         struct s1 {int (*f) (int a);};
 357         struct s2 {int (*f) (double a);};],
 358         [cf_cv_ansi_cc="$cf_arg"; break])
 359 done
 360 CFLAGS="$cf_save_CFLAGS"
 361 CPPFLAGS="$cf_save_CPPFLAGS"
 362 ])
 363
 364 if test "$cf_cv_ansi_cc" != "no"; then
 365 if test ".$cf_cv_ansi_cc" != ".-DCC_HAS_PROTOS"; then
 366         CF_ADD_CFLAGS($cf_cv_ansi_cc)
 367 else
 368         AC_DEFINE(CC_HAS_PROTOS)
 369 fi
 370 fi
 371 ])dnl
 372 dnl ---------------------------------------------------------------------------
 373 dnl CF_ANSI_CC_REQD version: 4 updated: 2008/03/23 14:48:54
 374 dnl ---------------
 375 dnl For programs that must use an ANSI compiler, obtain compiler options that
 376 dnl will make it recognize prototypes.  We'll do preprocessor checks in other
 377 dnl macros, since tools such as unproto can fake prototypes, but only part of
 378 dnl the preprocessor.
 379 AC_DEFUN([CF_ANSI_CC_REQD],
 380 [AC_REQUIRE([CF_ANSI_CC_CHECK])
 381 if test "$cf_cv_ansi_cc" = "no"; then
 382         AC_MSG_ERROR(
 383 [Your compiler does not appear to recognize prototypes.
 384 You have the following choices:
 385         a. adjust your compiler options
 386         b. get an up-to-date compiler
 387         c. use a wrapper such as unproto])
 388 fi
 389 ])dnl
 390 dnl ---------------------------------------------------------------------------
 391 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 392 dnl --------------
 393 dnl Allow user to disable a normally-on option.
 394 AC_DEFUN([CF_ARG_DISABLE],
 395 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 396 dnl ---------------------------------------------------------------------------
 397 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 398 dnl -------------
 399 dnl Allow user to enable a normally-off option.
 400 AC_DEFUN([CF_ARG_ENABLE],
 401 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 402 dnl ---------------------------------------------------------------------------
 403 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 404 dnl -------------
 405 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 406 dnl values.
 407 dnl
 408 dnl Parameters:
 409 dnl $1 = option name
 410 dnl $2 = help-string
 411 dnl $3 = action to perform if option is not default
 412 dnl $4 = action if perform if option is default
 413 dnl $5 = default option value (either 'yes' or 'no')
 414 AC_DEFUN([CF_ARG_OPTION],
 415 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 416   if test "$enableval" != "$5" ; then
 417 ifelse([$3],,[    :]dnl
 418 ,[    $3]) ifelse([$4],,,[
 419   else
 420     $4])
 421   fi],[enableval=$5 ifelse([$4],,,[
 422   $4
 423 ])dnl
 424   ])])dnl
 425 dnl ---------------------------------------------------------------------------
 426 dnl CF_CHECK_CACHE version: 11 updated: 2008/03/23 14:45:59
 427 dnl --------------
 428 dnl Check if we're accidentally using a cache from a different machine.
 429 dnl Derive the system name, as a check for reusing the autoconf cache.
 430 dnl
 431 dnl If we've packaged config.guess and config.sub, run that (since it does a
 432 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 433 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 434 dnl which is useful in cross-compiles.
 435 dnl
 436 dnl Note: we would use $ac_config_sub, but that is one of the places where
 437 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 438 AC_DEFUN([CF_CHECK_CACHE],
 439 [
 440 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 441         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 442         system_name="$host_os"
 443 else
 444         system_name="`(uname -s -r) 2>/dev/null`"
 445         if test -z "$system_name" ; then
 446                 system_name="`(hostname) 2>/dev/null`"
 447         fi
 448 fi
 449 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name")
 450 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 451
 452 test -z "$system_name" && system_name="$cf_cv_system_name"
 453 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 454
 455 if test ".$system_name" != ".$cf_cv_system_name" ; then
 456         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 457         AC_MSG_ERROR("Please remove config.cache and try again.")
 458 fi
 459 ])dnl
 460 dnl ---------------------------------------------------------------------------
 461 dnl CF_CHECK_CFLAGS version: 2 updated: 2001/12/30 19:09:58
 462 dnl ---------------
 463 dnl Conditionally add to $CFLAGS and $CPPFLAGS values which are derived from
 464 dnl a build-configuration such as imake.  These have the pitfall that they
 465 dnl often contain compiler-specific options which we cannot use, mixed with
 466 dnl preprocessor options that we usually can.
 467 AC_DEFUN([CF_CHECK_CFLAGS],
 468 [
 469 CF_VERBOSE(checking additions to CFLAGS)
 470 cf_check_cflags="$CFLAGS"
 471 cf_check_cppflags="$CPPFLAGS"
 472 CF_ADD_CFLAGS($1,yes)
 473 if test "$cf_check_cflags" != "$CFLAGS" ; then
 474 AC_TRY_LINK([#include <stdio.h>],[printf("Hello world");],,
 475         [CF_VERBOSE(test-compile failed.  Undoing change to \$CFLAGS)
 476          if test "$cf_check_cppflags" != "$CPPFLAGS" ; then
 477                  CF_VERBOSE(but keeping change to \$CPPFLAGS)
 478          fi
 479          CFLAGS="$cf_check_flags"])
 480 fi
 481 ])dnl
 482 dnl ---------------------------------------------------------------------------
 483 dnl CF_CURSES_ACS_MAP version: 6 updated: 2010/10/23 15:54:49
 484 dnl -----------------
 485 dnl Check for likely values of acs_map[]:
 486 AC_DEFUN([CF_CURSES_ACS_MAP],
 487 [
 488 AC_REQUIRE([CF_NCURSES_WRAP_PREFIX])dnl
 489 AC_CACHE_CHECK(for alternate character set array, cf_cv_curses_acs_map,[
 490 cf_cv_curses_acs_map=unknown
 491 for name in acs_map _acs_map __acs_map ${NCURSES_WRAP_PREFIX}acs_map
 492 do
 493 AC_TRY_LINK([
 494 #include <${cf_cv_ncurses_header:-curses.h}>
 495 ],[
 496 $name['k'] = ACS_PLUS
 497 ],[cf_cv_curses_acs_map=$name; break])
 498 done
 499 ])
 500
 501 test "$cf_cv_curses_acs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_ACS_ARRAY,$cf_cv_curses_acs_map)
 502 ])
 503 dnl ---------------------------------------------------------------------------
 504 dnl CF_CURSES_CHECK_DATA version: 4 updated: 2011/01/15 16:39:24
 505 dnl --------------------
 506 dnl Check if curses.h defines the given data/variable.
 507 dnl Use this after CF_NCURSES_CONFIG or CF_CURSES_CONFIG.
 508 AC_DEFUN([CF_CURSES_CHECK_DATA],
 509 [
 510 AC_MSG_CHECKING(for data $1 declaration in ${cf_cv_ncurses_header:-curses.h})
 511
 512 AC_TRY_COMPILE(CF__CURSES_HEAD,[
 513 void *foo = &($1)
 514 ],cf_result=yes,cf_result=no)
 515 AC_MSG_RESULT($cf_result)
 516
 517 if test $cf_result = yes ; then
 518         CF_UPPER(cf_result,have_curses_data_$1)
 519         AC_DEFINE_UNQUOTED($cf_result)
 520 else
 521         AC_MSG_CHECKING(for data $1 in library)
 522         # BSD linkers insist on making weak linkage, but resolve at runtime.
 523         AC_TRY_RUN(CF__CURSES_HEAD
 524 [
 525 extern char $1;
 526 int main(void)
 527 {
 528         void *foo = &($1);
 529         ${cf_cv_main_return:-return}(foo == 0);
 530 }],[cf_result=yes],[cf_result=no],[
 531         # cross-compiling
 532         AC_TRY_LINK(CF__CURSES_HEAD
 533 [extern char $1;],[
 534         do {
 535                 void *foo = &($1);
 536                 ${cf_cv_main_return:-return}(foo == 0);
 537         } while (0)
 538 ],[cf_result=yes],[cf_result=no])
 539 ])
 540         AC_MSG_RESULT($cf_result)
 541         if test $cf_result = yes ; then
 542                 CF_UPPER(cf_result,decl_curses_data_$1)
 543                 AC_DEFINE_UNQUOTED($cf_result)
 544         fi
 545 fi
 546 ])dnl
 547 dnl ---------------------------------------------------------------------------
 548 dnl CF_CURSES_CHECK_TYPE version: 3 updated: 2010/10/23 15:54:49
 549 dnl --------------------
 550 dnl Check if curses.h defines the given type
 551 AC_DEFUN([CF_CURSES_CHECK_TYPE],
 552 [
 553 AC_MSG_CHECKING(for type $1 in ${cf_cv_ncurses_header:-curses.h})
 554 AC_TRY_COMPILE([
 555 #ifndef _XOPEN_SOURCE_EXTENDED
 556 #define _XOPEN_SOURCE_EXTENDED
 557 #endif
 558 #include <${cf_cv_ncurses_header:-curses.h}>],[
 559 $1 foo
 560 ],cf_result=yes,cf_result=no)
 561 AC_MSG_RESULT($cf_result)
 562 if test $cf_result = yes ; then
 563         CF_UPPER(cf_result,have_type_$1)
 564         AC_DEFINE_UNQUOTED($cf_result)
 565 else
 566         AC_DEFINE_UNQUOTED($1,$2)
 567 fi
 568 ])dnl
 569 dnl ---------------------------------------------------------------------------
 570 dnl CF_CURSES_CONFIG version: 2 updated: 2006/10/29 11:06:27
 571 dnl ----------------
 572 dnl Tie together the configure-script macros for curses.  It may be ncurses,
 573 dnl but unless asked, we do not make a special search for ncurses.  However,
 574 dnl still check for the ncurses version number, for use in other macros.
 575 AC_DEFUN([CF_CURSES_CONFIG],
 576 [
 577 CF_CURSES_CPPFLAGS
 578 CF_NCURSES_VERSION
 579 CF_CURSES_LIBS
 580 ])dnl
 581 dnl ---------------------------------------------------------------------------
 582 dnl CF_CURSES_CPPFLAGS version: 11 updated: 2011/04/09 14:51:08
 583 dnl ------------------
 584 dnl Look for the curses headers.
 585 AC_DEFUN([CF_CURSES_CPPFLAGS],[
 586
 587 AC_CACHE_CHECK(for extra include directories,cf_cv_curses_incdir,[
 588 cf_cv_curses_incdir=no
 589 case $host_os in #(vi
 590 hpux10.*) #(vi
 591         if test "x$cf_cv_screen" = "xcurses_colr"
 592         then
 593                 test -d /usr/include/curses_colr && \
 594                 cf_cv_curses_incdir="-I/usr/include/curses_colr"
 595         fi
 596         ;;
 597 sunos3*|sunos4*)
 598         if test "x$cf_cv_screen" = "xcurses_5lib"
 599         then
 600                 test -d /usr/5lib && \
 601                 test -d /usr/5include && \
 602                 cf_cv_curses_incdir="-I/usr/5include"
 603         fi
 604         ;;
 605 esac
 606 ])
 607 test "$cf_cv_curses_incdir" != no && CPPFLAGS="$CPPFLAGS $cf_cv_curses_incdir"
 608
 609 CF_CURSES_HEADER
 610 CF_TERM_HEADER
 611 ])dnl
 612 dnl ---------------------------------------------------------------------------
 613 dnl CF_CURSES_FUNCS version: 17 updated: 2011/05/14 16:07:29
 614 dnl ---------------
 615 dnl Curses-functions are a little complicated, since a lot of them are macros.
 616 AC_DEFUN([CF_CURSES_FUNCS],
 617 [
 618 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 619 AC_REQUIRE([CF_XOPEN_CURSES])
 620 AC_REQUIRE([CF_CURSES_TERM_H])
 621 AC_REQUIRE([CF_CURSES_UNCTRL_H])
 622 for cf_func in $1
 623 do
 624         CF_UPPER(cf_tr_func,$cf_func)
 625         AC_MSG_CHECKING(for ${cf_func})
 626         CF_MSG_LOG(${cf_func})
 627         AC_CACHE_VAL(cf_cv_func_$cf_func,[
 628                 eval cf_result='$ac_cv_func_'$cf_func
 629                 if test ".$cf_result" != ".no"; then
 630                         AC_TRY_LINK(CF__CURSES_HEAD,
 631                         [
 632 #ifndef ${cf_func}
 633 long foo = (long)(&${cf_func});
 634 if (foo + 1234 > 5678)
 635         ${cf_cv_main_return:-return}(foo);
 636 #endif
 637                         ],
 638                         [cf_result=yes],
 639                         [cf_result=no])
 640                 fi
 641                 eval 'cf_cv_func_'$cf_func'=$cf_result'
 642         ])
 643         # use the computed/retrieved cache-value:
 644         eval 'cf_result=$cf_cv_func_'$cf_func
 645         AC_MSG_RESULT($cf_result)
 646         if test $cf_result != no; then
 647                 AC_DEFINE_UNQUOTED(HAVE_${cf_tr_func})
 648         fi
 649 done
 650 ])dnl
 651 dnl ---------------------------------------------------------------------------
 652 dnl CF_CURSES_HEADER version: 3 updated: 2011/05/01 19:47:45
 653 dnl ----------------
 654 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
 655 dnl variations of ncurses' installs.
 656 dnl
 657 dnl $1 = ncurses when looking for ncurses, or is empty
 658 AC_DEFUN([CF_CURSES_HEADER],[
 659 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
 660 cf_cv_ncurses_header=none
 661 for cf_header in ifelse($1,,,[ \
 662     $1/ncurses.h \
 663         $1/curses.h]) \
 664         ncurses.h \
 665         curses.h ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
 666 do
 667 AC_TRY_COMPILE([#include <${cf_header}>],
 668         [initscr(); tgoto("?", 0,0)],
 669         [cf_cv_ncurses_header=$cf_header; break],[])
 670 done
 671 ])
 672
 673 if test "$cf_cv_ncurses_header" = none ; then
 674         AC_MSG_ERROR(No curses header-files found)
 675 fi
 676
 677 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
 678 AC_CHECK_HEADERS($cf_cv_ncurses_header)
 679 ])dnl
 680 dnl ---------------------------------------------------------------------------
 681 dnl CF_CURSES_LIBS version: 35 updated: 2011/08/09 21:06:37
 682 dnl --------------
 683 dnl Look for the curses libraries.  Older curses implementations may require
 684 dnl termcap/termlib to be linked as well.  Call CF_CURSES_CPPFLAGS first.
 685 AC_DEFUN([CF_CURSES_LIBS],[
 686
 687 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 688 AC_MSG_CHECKING(if we have identified curses libraries)
 689 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 690     [initscr(); tgoto("?", 0,0)],
 691     cf_result=yes,
 692     cf_result=no)
 693 AC_MSG_RESULT($cf_result)
 694
 695 if test "$cf_result" = no ; then
 696 case $host_os in #(vi
 697 freebsd*) #(vi
 698     AC_CHECK_LIB(mytinfo,tgoto,[CF_ADD_LIBS(-lmytinfo)])
 699     ;;
 700 hpux10.*) #(vi
 701         # Looking at HPUX 10.20, the Hcurses library is the oldest (1997), cur_colr
 702         # next (1998), and xcurses "newer" (2000).  There is no header file for
 703         # Hcurses; the subdirectory curses_colr has the headers (curses.h and
 704         # term.h) for cur_colr
 705         if test "x$cf_cv_screen" = "xcurses_colr"
 706         then
 707                 AC_CHECK_LIB(cur_colr,initscr,[
 708                         CF_ADD_LIBS(-lcur_colr)
 709                         ac_cv_func_initscr=yes
 710                         ],[
 711                 AC_CHECK_LIB(Hcurses,initscr,[
 712                         # HP's header uses __HP_CURSES, but user claims _HP_CURSES.
 713                         CF_ADD_LIBS(-lHcurses)
 714                         CPPFLAGS="$CPPFLAGS -D__HP_CURSES -D_HP_CURSES"
 715                         ac_cv_func_initscr=yes
 716                         ])])
 717         fi
 718     ;;
 719 linux*)
 720         case `arch 2>/dev/null` in
 721         x86_64)
 722                 if test -d /lib64
 723                 then
 724                         CF_ADD_LIBDIR(/lib64)
 725                 else
 726                         CF_ADD_LIBDIR(/lib)
 727                 fi
 728                 ;;
 729         *)
 730                 CF_ADD_LIBDIR(/lib)
 731                 ;;
 732         esac
 733     ;;
 734 sunos3*|sunos4*)
 735         if test "x$cf_cv_screen" = "xcurses_5lib"
 736         then
 737                 if test -d /usr/5lib ; then
 738                         CF_ADD_LIBDIR(/usr/5lib)
 739                         CF_ADD_LIBS(-lcurses -ltermcap)
 740                 fi
 741     fi
 742     ac_cv_func_initscr=yes
 743     ;;
 744 esac
 745
 746 if test ".$ac_cv_func_initscr" != .yes ; then
 747     cf_save_LIBS="$LIBS"
 748     cf_term_lib=""
 749     cf_curs_lib=""
 750
 751     if test ".${cf_cv_ncurses_version:-no}" != .no
 752     then
 753         cf_check_list="ncurses curses cursesX"
 754     else
 755         cf_check_list="cursesX curses ncurses"
 756     fi
 757
 758     # Check for library containing tgoto.  Do this before curses library
 759     # because it may be needed to link the test-case for initscr.
 760     AC_CHECK_FUNC(tgoto,[cf_term_lib=predefined],[
 761         for cf_term_lib in $cf_check_list otermcap termcap termlib unknown
 762         do
 763             AC_CHECK_LIB($cf_term_lib,tgoto,[break])
 764         done
 765     ])
 766
 767     # Check for library containing initscr
 768     test "$cf_term_lib" != predefined && test "$cf_term_lib" != unknown && LIBS="-l$cf_term_lib $cf_save_LIBS"
 769         for cf_curs_lib in $cf_check_list xcurses jcurses pdcurses unknown
 770     do
 771         AC_CHECK_LIB($cf_curs_lib,initscr,[break])
 772     done
 773     test $cf_curs_lib = unknown && AC_MSG_ERROR(no curses library found)
 774
 775     LIBS="-l$cf_curs_lib $cf_save_LIBS"
 776     if test "$cf_term_lib" = unknown ; then
 777         AC_MSG_CHECKING(if we can link with $cf_curs_lib library)
 778         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 779             [initscr()],
 780             [cf_result=yes],
 781             [cf_result=no])
 782         AC_MSG_RESULT($cf_result)
 783         test $cf_result = no && AC_MSG_ERROR(Cannot link curses library)
 784     elif test "$cf_curs_lib" = "$cf_term_lib" ; then
 785         :
 786     elif test "$cf_term_lib" != predefined ; then
 787         AC_MSG_CHECKING(if we need both $cf_curs_lib and $cf_term_lib libraries)
 788         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 789             [initscr(); tgoto((char *)0, 0, 0);],
 790             [cf_result=no],
 791             [
 792             LIBS="-l$cf_curs_lib -l$cf_term_lib $cf_save_LIBS"
 793             AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 794                 [initscr()],
 795                 [cf_result=yes],
 796                 [cf_result=error])
 797             ])
 798         AC_MSG_RESULT($cf_result)
 799     fi
 800 fi
 801 fi
 802
 803 ])dnl
 804 dnl ---------------------------------------------------------------------------
 805 dnl CF_CURSES_TERM_H version: 9 updated: 2011/04/09 18:19:55
 806 dnl ----------------
 807 dnl SVr4 curses should have term.h as well (where it puts the definitions of
 808 dnl the low-level interface).  This may not be true in old/broken implementations,
 809 dnl as well as in misconfigured systems (e.g., gcc configured for Solaris 2.4
 810 dnl running with Solaris 2.5.1).
 811 AC_DEFUN([CF_CURSES_TERM_H],
 812 [
 813 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 814
 815 AC_CACHE_CHECK(for term.h, cf_cv_term_header,[
 816
 817 # If we found <ncurses/curses.h>, look for <ncurses/term.h>, but always look
 818 # for <term.h> if we do not find the variant.
 819
 820 cf_header_list="term.h ncurses/term.h ncursesw/term.h"
 821
 822 case ${cf_cv_ncurses_header:-curses.h} in #(vi
 823 */*)
 824         cf_header_item=`echo ${cf_cv_ncurses_header:-curses.h} | sed -e 's%\..*%%' -e 's%/.*%/%'`term.h
 825         cf_header_list="$cf_header_item $cf_header_list"
 826         ;;
 827 esac
 828
 829 for cf_header in $cf_header_list
 830 do
 831         AC_TRY_COMPILE([
 832 #include <${cf_cv_ncurses_header:-curses.h}>
 833 #include <${cf_header}>],
 834         [WINDOW *x],
 835         [cf_cv_term_header=$cf_header
 836          break],
 837         [cf_cv_term_header=no])
 838 done
 839
 840 case $cf_cv_term_header in #(vi
 841 no)
 842         # If curses is ncurses, some packagers still mess it up by trying to make
 843         # us use GNU termcap.  This handles the most common case.
 844         for cf_header in ncurses/term.h ncursesw/term.h
 845         do
 846                 AC_TRY_COMPILE([
 847 #include <${cf_cv_ncurses_header:-curses.h}>
 848 #ifdef NCURSES_VERSION
 849 #include <${cf_header}>
 850 #else
 851 make an error
 852 #endif],
 853                         [WINDOW *x],
 854                         [cf_cv_term_header=$cf_header
 855                          break],
 856                         [cf_cv_term_header=no])
 857         done
 858         ;;
 859 esac
 860 ])
 861
 862 case $cf_cv_term_header in #(vi
 863 term.h) #(vi
 864         AC_DEFINE(HAVE_TERM_H)
 865         ;;
 866 ncurses/term.h) #(vi
 867         AC_DEFINE(HAVE_NCURSES_TERM_H)
 868         ;;
 869 ncursesw/term.h)
 870         AC_DEFINE(HAVE_NCURSESW_TERM_H)
 871         ;;
 872 esac
 873 ])dnl
 874 dnl ---------------------------------------------------------------------------
 875 dnl CF_CURSES_UNCTRL_H version: 1 updated: 2011/04/09 18:19:55
 876 dnl ------------------
 877 dnl Any X/Open curses implementation must have unctrl.h, but ncurses packages
 878 dnl may put it in a subdirectory (along with ncurses' other headers, of
 879 dnl course).  Packages which put the headers in inconsistent locations are
 880 dnl broken).
 881 AC_DEFUN([CF_CURSES_UNCTRL_H],
 882 [
 883 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 884
 885 AC_CACHE_CHECK(for unctrl.h, cf_cv_unctrl_header,[
 886
 887 # If we found <ncurses/curses.h>, look for <ncurses/unctrl.h>, but always look
 888 # for <unctrl.h> if we do not find the variant.
 889
 890 cf_header_list="unctrl.h ncurses/unctrl.h ncursesw/unctrl.h"
 891
 892 case ${cf_cv_ncurses_header:-curses.h} in #(vi
 893 */*)
 894         cf_header_item=`echo ${cf_cv_ncurses_header:-curses.h} | sed -e 's%\..*%%' -e 's%/.*%/%'`unctrl.h
 895         cf_header_list="$cf_header_item $cf_header_list"
 896         ;;
 897 esac
 898
 899 for cf_header in $cf_header_list
 900 do
 901         AC_TRY_COMPILE([
 902 #include <${cf_cv_ncurses_header:-curses.h}>
 903 #include <${cf_header}>],
 904         [WINDOW *x],
 905         [cf_cv_unctrl_header=$cf_header
 906          break],
 907         [cf_cv_unctrl_header=no])
 908 done
 909
 910 case $cf_cv_unctrl_header in #(vi
 911 no)
 912         AC_MSG_WARN(unctrl.h header not found)
 913         ;;
 914 esac
 915 ])
 916
 917 case $cf_cv_unctrl_header in #(vi
 918 unctrl.h) #(vi
 919         AC_DEFINE(HAVE_UNCTRL_H)
 920         ;;
 921 ncurses/unctrl.h) #(vi
 922         AC_DEFINE(HAVE_NCURSES_UNCTRL_H)
 923         ;;
 924 ncursesw/unctrl.h)
 925         AC_DEFINE(HAVE_NCURSESW_UNCTRL_H)
 926         ;;
 927 esac
 928 ])dnl
 929 dnl ---------------------------------------------------------------------------
 930 dnl CF_CURSES_WACS_MAP version: 5 updated: 2011/01/15 11:28:59
 931 dnl ------------------
 932 dnl Check for likely values of wacs_map[].
 933 AC_DEFUN([CF_CURSES_WACS_MAP],
 934 [
 935 AC_CACHE_CHECK(for wide alternate character set array, cf_cv_curses_wacs_map,[
 936         cf_cv_curses_wacs_map=unknown
 937         for name in wacs_map _wacs_map __wacs_map _nc_wacs _wacs_char
 938         do
 939         AC_TRY_LINK([
 940 #ifndef _XOPEN_SOURCE_EXTENDED
 941 #define _XOPEN_SOURCE_EXTENDED
 942 #endif
 943 #include <${cf_cv_ncurses_header:-curses.h}>],
 944         [void *foo = &($name['k'])],
 945         [cf_cv_curses_wacs_map=$name
 946          break])
 947         done])
 948
 949 test "$cf_cv_curses_wacs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_WACS_ARRAY,$cf_cv_curses_wacs_map)
 950 ])dnl
 951 dnl ---------------------------------------------------------------------------
 952 dnl CF_CURSES_WACS_SYMBOLS version: 1 updated: 2011/01/15 11:28:59
 953 dnl ----------------------
 954 dnl Do a check to see if the WACS_xxx constants are defined compatibly with
 955 dnl X/Open Curses.  In particular, NetBSD's implementation of the WACS_xxx
 956 dnl constants is broken since those constants do not point to cchar_t's.
 957 AC_DEFUN([CF_CURSES_WACS_SYMBOLS],
 958 [
 959 AC_REQUIRE([CF_CURSES_WACS_MAP])
 960
 961 AC_CACHE_CHECK(for wide alternate character constants, cf_cv_curses_wacs_symbols,[
 962 cf_cv_curses_wacs_symbols=no
 963 if test "$cf_cv_curses_wacs_map" != unknown
 964 then
 965         AC_TRY_LINK([
 966 #ifndef _XOPEN_SOURCE_EXTENDED
 967 #define _XOPEN_SOURCE_EXTENDED
 968 #endif
 969 #include <${cf_cv_ncurses_header:-curses.h}>],
 970         [cchar_t *foo = WACS_PLUS;
 971          $cf_cv_curses_wacs_map['k'] = *WACS_PLUS],
 972         [cf_cv_curses_wacs_symbols=yes])
 973 else
 974         AC_TRY_LINK([
 975 #ifndef _XOPEN_SOURCE_EXTENDED
 976 #define _XOPEN_SOURCE_EXTENDED
 977 #endif
 978 #include <${cf_cv_ncurses_header:-curses.h}>],
 979         [cchar_t *foo = WACS_PLUS],
 980         [cf_cv_curses_wacs_symbols=yes])
 981 fi
 982 ])
 983
 984 test "$cf_cv_curses_wacs_symbols" != no && AC_DEFINE(CURSES_WACS_SYMBOLS)
 985 ])dnl
 986 dnl ---------------------------------------------------------------------------
 987 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
 988 dnl ----------
 989 dnl "dirname" is not portable, so we fake it with a shell script.
 990 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
 991 dnl ---------------------------------------------------------------------------
 992 dnl CF_DISABLE_ECHO version: 11 updated: 2009/12/13 13:16:57
 993 dnl ---------------
 994 dnl You can always use "make -n" to see the actual options, but it's hard to
 995 dnl pick out/analyze warning messages when the compile-line is long.
 996 dnl
 997 dnl Sets:
 998 dnl     ECHO_LT - symbol to control if libtool is verbose
 999 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1000 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1001 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1002 dnl     ECHO_CC - symbol to put before any "cc" line
1003 dnl
1004 AC_DEFUN([CF_DISABLE_ECHO],[
1005 AC_MSG_CHECKING(if you want to see long compiling messages)
1006 CF_ARG_DISABLE(echo,
1007         [  --disable-echo          display "compiling" commands],
1008         [
1009     ECHO_LT='--silent'
1010     ECHO_LD='@echo linking [$]@;'
1011     RULE_CC='@echo compiling [$]<'
1012     SHOW_CC='@echo compiling [$]@'
1013     ECHO_CC='@'
1014 ],[
1015     ECHO_LT=''
1016     ECHO_LD=''
1017     RULE_CC=''
1018     SHOW_CC=''
1019     ECHO_CC=''
1020 ])
1021 AC_MSG_RESULT($enableval)
1022 AC_SUBST(ECHO_LT)
1023 AC_SUBST(ECHO_LD)
1024 AC_SUBST(RULE_CC)
1025 AC_SUBST(SHOW_CC)
1026 AC_SUBST(ECHO_CC)
1027 ])dnl
1028 dnl ---------------------------------------------------------------------------
1029 dnl CF_DISABLE_LEAKS version: 6 updated: 2010/07/23 04:14:32
1030 dnl ----------------
1031 dnl Combine no-leak checks with the libraries or tools that are used for the
1032 dnl checks.
1033 AC_DEFUN([CF_DISABLE_LEAKS],[
1034
1035 AC_REQUIRE([CF_WITH_DMALLOC])
1036 AC_REQUIRE([CF_WITH_DBMALLOC])
1037 AC_REQUIRE([CF_WITH_VALGRIND])
1038
1039 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1040 AC_ARG_ENABLE(leaks,
1041         [  --disable-leaks         test: free permanent memory, analyze leaks],
1042         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1043         : ${with_no_leaks:=no})
1044 AC_MSG_RESULT($with_no_leaks)
1045
1046 if test "$with_no_leaks" = yes ; then
1047         AC_DEFINE(NO_LEAKS)
1048         AC_DEFINE(YY_NO_LEAKS)
1049 fi
1050 ])dnl
1051 dnl ---------------------------------------------------------------------------
1052 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1053 dnl ---------------------
1054 dnl The rpath-hack makes it simpler to build programs, particularly with the
1055 dnl *BSD ports which may have essential libraries in unusual places.  But it
1056 dnl can interfere with building an executable for the base system.  Use this
1057 dnl option in that case.
1058 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1059 [
1060 AC_MSG_CHECKING(if rpath-hack should be disabled)
1061 CF_ARG_DISABLE(rpath-hack,
1062         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1063         [cf_disable_rpath_hack=yes],
1064         [cf_disable_rpath_hack=no])
1065 AC_MSG_RESULT($cf_disable_rpath_hack)
1066 if test "$cf_disable_rpath_hack" = no ; then
1067         CF_RPATH_HACK
1068 fi
1069 ])
1070 dnl ---------------------------------------------------------------------------
1071 dnl CF_ENABLE_WARNINGS version: 4 updated: 2009/07/26 17:53:03
1072 dnl ------------------
1073 dnl Configure-option to enable gcc warnings
1074 AC_DEFUN([CF_ENABLE_WARNINGS],[
1075 if ( test "$GCC" = yes || test "$GXX" = yes )
1076 then
1077 AC_MSG_CHECKING(if you want to turn on gcc warnings)
1078 CF_ARG_ENABLE(warnings,
1079         [  --enable-warnings       test: turn on gcc compiler warnings],
1080         [with_warnings=yes],
1081         [with_warnings=no])
1082 AC_MSG_RESULT($with_warnings)
1083 if test "$with_warnings" = "yes"
1084 then
1085         CF_GCC_ATTRIBUTES
1086         CF_GCC_WARNINGS
1087 fi
1088 fi
1089 ])dnl
1090 dnl ---------------------------------------------------------------------------
1091 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
1092 dnl ---------------
1093 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
1094 dnl prefer a standard location, and use -L options only if we do not find the
1095 dnl library in the standard library location(s).
1096 dnl     $1 = library name
1097 dnl     $2 = library class, usually the same as library name
1098 dnl     $3 = includes
1099 dnl     $4 = code fragment to compile/link
1100 dnl     $5 = corresponding function-name
1101 dnl     $6 = flag, nonnull if failure should not cause an error-exit
1102 dnl
1103 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
1104 dnl to use a -L option.
1105 AC_DEFUN([CF_FIND_LIBRARY],
1106 [
1107         eval 'cf_cv_have_lib_'$1'=no'
1108         cf_libdir=""
1109         AC_CHECK_FUNC($5,
1110                 eval 'cf_cv_have_lib_'$1'=yes',[
1111                 cf_save_LIBS="$LIBS"
1112                 AC_MSG_CHECKING(for $5 in -l$1)
1113                 LIBS="-l$1 $LIBS"
1114                 AC_TRY_LINK([$3],[$4],
1115                         [AC_MSG_RESULT(yes)
1116                          eval 'cf_cv_have_lib_'$1'=yes'
1117                         ],
1118                         [AC_MSG_RESULT(no)
1119                         CF_LIBRARY_PATH(cf_search,$2)
1120                         for cf_libdir in $cf_search
1121                         do
1122                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
1123                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
1124                                 AC_TRY_LINK([$3],[$4],
1125                                         [AC_MSG_RESULT(yes)
1126                                          eval 'cf_cv_have_lib_'$1'=yes'
1127                                          break],
1128                                         [AC_MSG_RESULT(no)
1129                                          LIBS="$cf_save_LIBS"])
1130                         done
1131                         ])
1132                 ])
1133 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
1134 ifelse($6,,[
1135 if test $cf_found_library = no ; then
1136         AC_MSG_ERROR(Cannot link $1 library)
1137 fi
1138 ])
1139 ])dnl
1140 dnl ---------------------------------------------------------------------------
1141 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1142 dnl ---------------
1143 dnl Find a library (specifically the linkage used in the code fragment),
1144 dnl searching for it if it is not already in the library path.
1145 dnl See also CF_ADD_SEARCHPATH.
1146 dnl
1147 dnl Parameters (4-on are optional):
1148 dnl     $1 = headers for library entrypoint
1149 dnl     $2 = code fragment for library entrypoint
1150 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1151 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1152 dnl     $5 = action to perform if not successful
1153 dnl     $6 = module name, if not the same as the library name
1154 dnl     $7 = extra libraries
1155 dnl
1156 dnl Sets these variables:
1157 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1158 dnl     $cf_cv_header_path_$3 - include-directory if needed
1159 dnl     $cf_cv_library_path_$3 - library-directory if needed
1160 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1161 AC_DEFUN([CF_FIND_LINKAGE],[
1162
1163 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1164 # will be set on completion of the AC_TRY_LINK below.
1165 cf_cv_header_path_$3=
1166 cf_cv_library_path_$3=
1167
1168 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1169
1170 cf_save_LIBS="$LIBS"
1171
1172 AC_TRY_LINK([$1],[$2],[
1173         cf_cv_find_linkage_$3=yes
1174         cf_cv_header_path_$3=/usr/include
1175         cf_cv_library_path_$3=/usr/lib
1176 ],[
1177
1178 LIBS="-l$3 $7 $cf_save_LIBS"
1179
1180 AC_TRY_LINK([$1],[$2],[
1181         cf_cv_find_linkage_$3=yes
1182         cf_cv_header_path_$3=/usr/include
1183         cf_cv_library_path_$3=/usr/lib
1184         cf_cv_library_file_$3="-l$3"
1185 ],[
1186         cf_cv_find_linkage_$3=no
1187         LIBS="$cf_save_LIBS"
1188
1189     CF_VERBOSE(find linkage for $3 library)
1190     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1191
1192     cf_save_CPPFLAGS="$CPPFLAGS"
1193     cf_test_CPPFLAGS="$CPPFLAGS"
1194
1195     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1196     for cf_cv_header_path_$3 in $cf_search
1197     do
1198       if test -d $cf_cv_header_path_$3 ; then
1199         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1200         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1201         AC_TRY_COMPILE([$1],[$2],[
1202             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1203             cf_cv_find_linkage_$3=maybe
1204             cf_test_CPPFLAGS="$CPPFLAGS"
1205             break],[
1206             CPPFLAGS="$cf_save_CPPFLAGS"
1207             ])
1208       fi
1209     done
1210
1211     if test "$cf_cv_find_linkage_$3" = maybe ; then
1212
1213       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1214
1215       cf_save_LIBS="$LIBS"
1216       cf_save_LDFLAGS="$LDFLAGS"
1217
1218       ifelse([$6],,,[
1219         CPPFLAGS="$cf_test_CPPFLAGS"
1220         LIBS="-l$3 $7 $cf_save_LIBS"
1221         AC_TRY_LINK([$1],[$2],[
1222             CF_VERBOSE(... found $3 library in system)
1223             cf_cv_find_linkage_$3=yes])
1224             CPPFLAGS="$cf_save_CPPFLAGS"
1225             LIBS="$cf_save_LIBS"
1226             ])
1227
1228       if test "$cf_cv_find_linkage_$3" != yes ; then
1229         CF_LIBRARY_PATH(cf_search,$3)
1230         for cf_cv_library_path_$3 in $cf_search
1231         do
1232           if test -d $cf_cv_library_path_$3 ; then
1233             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1234             CPPFLAGS="$cf_test_CPPFLAGS"
1235             LIBS="-l$3 $7 $cf_save_LIBS"
1236             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1237             AC_TRY_LINK([$1],[$2],[
1238                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1239                 cf_cv_find_linkage_$3=yes
1240                 cf_cv_library_file_$3="-l$3"
1241                 break],[
1242                 CPPFLAGS="$cf_save_CPPFLAGS"
1243                 LIBS="$cf_save_LIBS"
1244                 LDFLAGS="$cf_save_LDFLAGS"
1245                 ])
1246           fi
1247         done
1248         CPPFLAGS="$cf_save_CPPFLAGS"
1249         LDFLAGS="$cf_save_LDFLAGS"
1250       fi
1251
1252     else
1253       cf_cv_find_linkage_$3=no
1254     fi
1255     ],$7)
1256 ])
1257
1258 LIBS="$cf_save_LIBS"
1259
1260 if test "$cf_cv_find_linkage_$3" = yes ; then
1261 ifelse([$4],,[
1262         CF_ADD_INCDIR($cf_cv_header_path_$3)
1263         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1264         CF_ADD_LIB($3)
1265 ],[$4])
1266 else
1267 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1268 fi
1269 ])dnl
1270 dnl ---------------------------------------------------------------------------
1271 dnl CF_FUNC_CURSES_VERSION version: 5 updated: 2010/10/23 15:54:49
1272 dnl ----------------------
1273 dnl Solaris has a data item 'curses_version', which confuses AC_CHECK_FUNCS.
1274 dnl It's a character string "SVR4", not documented.
1275 AC_DEFUN([CF_FUNC_CURSES_VERSION],
1276 [
1277 AC_CACHE_CHECK(for function curses_version, cf_cv_func_curses_version,[
1278 AC_TRY_RUN([
1279 #include <${cf_cv_ncurses_header:-curses.h}>
1280 int main()
1281 {
1282         char temp[1024];
1283         sprintf(temp, "%s\n", curses_version());
1284         ${cf_cv_main_return:-return}(0);
1285 }]
1286 ,[cf_cv_func_curses_version=yes]
1287 ,[cf_cv_func_curses_version=no]
1288 ,[cf_cv_func_curses_version=unknown])
1289 rm -f core])
1290 test "$cf_cv_func_curses_version" = yes && AC_DEFINE(HAVE_CURSES_VERSION)
1291 ])
1292 dnl ---------------------------------------------------------------------------
1293 dnl CF_GCC_ATTRIBUTES version: 14 updated: 2010/10/23 15:52:32
1294 dnl -----------------
1295 dnl Test for availability of useful gcc __attribute__ directives to quiet
1296 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1297 dnl to documentation, unrecognized directives cause older compilers to barf.
1298 AC_DEFUN([CF_GCC_ATTRIBUTES],
1299 [
1300 if test "$GCC" = yes
1301 then
1302 cat > conftest.i <<EOF
1303 #ifndef GCC_PRINTF
1304 #define GCC_PRINTF 0
1305 #endif
1306 #ifndef GCC_SCANF
1307 #define GCC_SCANF 0
1308 #endif
1309 #ifndef GCC_NORETURN
1310 #define GCC_NORETURN /* nothing */
1311 #endif
1312 #ifndef GCC_UNUSED
1313 #define GCC_UNUSED /* nothing */
1314 #endif
1315 EOF
1316 if test "$GCC" = yes
1317 then
1318         AC_CHECKING([for $CC __attribute__ directives])
1319 cat > conftest.$ac_ext <<EOF
1320 #line __oline__ "${as_me:-configure}"
1321 #include "confdefs.h"
1322 #include "conftest.h"
1323 #include "conftest.i"
1324 #if     GCC_PRINTF
1325 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1326 #else
1327 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1328 #endif
1329 #if     GCC_SCANF
1330 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1331 #else
1332 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1333 #endif
1334 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1335 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1336 extern void foo(void) GCC_NORETURN;
1337 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1338 EOF
1339         cf_printf_attribute=no
1340         cf_scanf_attribute=no
1341         for cf_attribute in scanf printf unused noreturn
1342         do
1343                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1344                 cf_directive="__attribute__(($cf_attribute))"
1345                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1346
1347                 case $cf_attribute in #(vi
1348                 printf) #(vi
1349                         cf_printf_attribute=yes
1350                         cat >conftest.h <<EOF
1351 #define GCC_$cf_ATTRIBUTE 1
1352 EOF
1353                         ;;
1354                 scanf) #(vi
1355                         cf_scanf_attribute=yes
1356                         cat >conftest.h <<EOF
1357 #define GCC_$cf_ATTRIBUTE 1
1358 EOF
1359                         ;;
1360                 *) #(vi
1361                         cat >conftest.h <<EOF
1362 #define GCC_$cf_ATTRIBUTE $cf_directive
1363 EOF
1364                         ;;
1365                 esac
1366
1367                 if AC_TRY_EVAL(ac_compile); then
1368                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1369                         cat conftest.h >>confdefs.h
1370                         case $cf_attribute in #(vi
1371                         printf) #(vi
1372                                 if test "$cf_printf_attribute" = no ; then
1373                                         cat >>confdefs.h <<EOF
1374 #define GCC_PRINTFLIKE(fmt,var) /* nothing */
1375 EOF
1376                                 else
1377                                         cat >>confdefs.h <<EOF
1378 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1379 EOF
1380                                 fi
1381                                 ;;
1382                         scanf) #(vi
1383                                 if test "$cf_scanf_attribute" = no ; then
1384                                         cat >>confdefs.h <<EOF
1385 #define GCC_SCANFLIKE(fmt,var) /* nothing */
1386 EOF
1387                                 else
1388                                         cat >>confdefs.h <<EOF
1389 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1390 EOF
1391                                 fi
1392                                 ;;
1393                         esac
1394                 fi
1395         done
1396 else
1397         fgrep define conftest.i >>confdefs.h
1398 fi
1399 rm -rf conftest*
1400 fi
1401 ])dnl
1402 dnl ---------------------------------------------------------------------------
1403 dnl CF_GCC_VERSION version: 5 updated: 2010/04/24 11:02:31
1404 dnl --------------
1405 dnl Find version of gcc
1406 AC_DEFUN([CF_GCC_VERSION],[
1407 AC_REQUIRE([AC_PROG_CC])
1408 GCC_VERSION=none
1409 if test "$GCC" = yes ; then
1410         AC_MSG_CHECKING(version of $CC)
1411         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1412         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1413         AC_MSG_RESULT($GCC_VERSION)
1414 fi
1415 ])dnl
1416 dnl ---------------------------------------------------------------------------
1417 dnl CF_GCC_WARNINGS version: 27 updated: 2010/10/23 15:52:32
1418 dnl ---------------
1419 dnl Check if the compiler supports useful warning options.  There's a few that
1420 dnl we don't use, simply because they're too noisy:
1421 dnl
1422 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1423 dnl     -Wredundant-decls (system headers make this too noisy)
1424 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1425 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1426 dnl             is enabled for ncurses using "--enable-const".
1427 dnl     -pedantic
1428 dnl
1429 dnl Parameter:
1430 dnl     $1 is an optional list of gcc warning flags that a particular
1431 dnl             application might want to use, e.g., "no-unused" for
1432 dnl             -Wno-unused
1433 dnl Special:
1434 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1435 dnl
1436 AC_DEFUN([CF_GCC_WARNINGS],
1437 [
1438 AC_REQUIRE([CF_GCC_VERSION])
1439 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1440
1441 cat > conftest.$ac_ext <<EOF
1442 #line __oline__ "${as_me:-configure}"
1443 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1444 EOF
1445
1446 if test "$INTEL_COMPILER" = yes
1447 then
1448 # The "-wdXXX" options suppress warnings:
1449 # remark #1419: external declaration in primary source file
1450 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1451 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1452 # remark #193: zero used for undefined preprocessing identifier
1453 # remark #593: variable "curs_sb_left_arrow" was set but never used
1454 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1455 # remark #869: parameter "tw" was never referenced
1456 # remark #981: operands are evaluated in unspecified order
1457 # warning #279: controlling expression is constant
1458
1459         AC_CHECKING([for $CC warning options])
1460         cf_save_CFLAGS="$CFLAGS"
1461         EXTRA_CFLAGS="-Wall"
1462         for cf_opt in \
1463                 wd1419 \
1464                 wd1683 \
1465                 wd1684 \
1466                 wd193 \
1467                 wd593 \
1468                 wd279 \
1469                 wd810 \
1470                 wd869 \
1471                 wd981
1472         do
1473                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1474                 if AC_TRY_EVAL(ac_compile); then
1475                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1476                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1477                 fi
1478         done
1479         CFLAGS="$cf_save_CFLAGS"
1480
1481 elif test "$GCC" = yes
1482 then
1483         AC_CHECKING([for $CC warning options])
1484         cf_save_CFLAGS="$CFLAGS"
1485         EXTRA_CFLAGS=
1486         cf_warn_CONST=""
1487         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1488         for cf_opt in W Wall \
1489                 Wbad-function-cast \
1490                 Wcast-align \
1491                 Wcast-qual \
1492                 Winline \
1493                 Wmissing-declarations \
1494                 Wmissing-prototypes \
1495                 Wnested-externs \
1496                 Wpointer-arith \
1497                 Wshadow \
1498                 Wstrict-prototypes \
1499                 Wundef $cf_warn_CONST $1
1500         do
1501                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1502                 if AC_TRY_EVAL(ac_compile); then
1503                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1504                         case $cf_opt in #(vi
1505                         Wcast-qual) #(vi
1506                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1507                                 ;;
1508                         Winline) #(vi
1509                                 case $GCC_VERSION in
1510                                 [[34]].*)
1511                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1512                                         continue;;
1513                                 esac
1514                                 ;;
1515                         esac
1516                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1517                 fi
1518         done
1519         CFLAGS="$cf_save_CFLAGS"
1520 fi
1521 rm -rf conftest*
1522
1523 AC_SUBST(EXTRA_CFLAGS)
1524 ])dnl
1525 dnl ---------------------------------------------------------------------------
1526 dnl CF_GETOPT_HEADER version: 4 updated: 2009/08/31 20:07:52
1527 dnl ----------------
1528 dnl Check for getopt's variables which are commonly defined in stdlib.h,
1529 dnl unistd.h or (nonstandard) in getopt.h
1530 AC_DEFUN([CF_GETOPT_HEADER],
1531 [
1532 AC_HAVE_HEADERS(unistd.h getopt.h)
1533 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
1534 cf_cv_getopt_header=none
1535 for cf_header in stdio.h stdlib.h unistd.h getopt.h
1536 do
1537 AC_TRY_COMPILE([
1538 #include <$cf_header>],
1539 [int x = optind; char *y = optarg],
1540 [cf_cv_getopt_header=$cf_header
1541  break])
1542 done
1543 ])
1544 if test $cf_cv_getopt_header != none ; then
1545         AC_DEFINE(HAVE_GETOPT_HEADER)
1546 fi
1547 ])dnl
1548 dnl ---------------------------------------------------------------------------
1549 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
1550 dnl -------------
1551 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1552 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1553 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1554 dnl since it is interwoven with GNU extensions.
1555 dnl
1556 dnl Well, yes we could work around it...
1557 AC_DEFUN([CF_GNU_SOURCE],
1558 [
1559 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1560 AC_TRY_COMPILE([#include <sys/types.h>],[
1561 #ifndef _XOPEN_SOURCE
1562 make an error
1563 #endif],
1564         [cf_cv_gnu_source=no],
1565         [cf_save="$CPPFLAGS"
1566          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1567          AC_TRY_COMPILE([#include <sys/types.h>],[
1568 #ifdef _XOPEN_SOURCE
1569 make an error
1570 #endif],
1571         [cf_cv_gnu_source=no],
1572         [cf_cv_gnu_source=yes])
1573         CPPFLAGS="$cf_save"
1574         ])
1575 ])
1576 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1577 ])dnl
1578 dnl ---------------------------------------------------------------------------
1579 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
1580 dnl --------------
1581 dnl Construct a search-list of directories for a nonstandard header-file
1582 dnl
1583 dnl Parameters
1584 dnl     $1 = the variable to return as result
1585 dnl     $2 = the package name
1586 AC_DEFUN([CF_HEADER_PATH],
1587 [
1588 $1=
1589
1590 # collect the current set of include-directories from compiler flags
1591 cf_header_path_list=""
1592 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1593         for cf_header_path in $CPPFLAGS $CFLAGS
1594         do
1595                 case $cf_header_path in #(vi
1596                 -I*)
1597                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1598                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1599                         cf_header_path_list="$cf_header_path_list [$]$1"
1600                         ;;
1601                 esac
1602         done
1603 fi
1604
1605 # add the variations for the package we are looking for
1606 CF_SUBDIR_PATH($1,$2,include)
1607
1608 test "$includedir" != NONE && \
1609 test "$includedir" != "/usr/include" && \
1610 test -d "$includedir" && {
1611         test -d $includedir &&    $1="[$]$1 $includedir"
1612         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1613 }
1614
1615 test "$oldincludedir" != NONE && \
1616 test "$oldincludedir" != "/usr/include" && \
1617 test -d "$oldincludedir" && {
1618         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1619         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1620 }
1621
1622 $1="[$]$1 $cf_header_path_list"
1623 ])dnl
1624 dnl ---------------------------------------------------------------------------
1625 dnl CF_INHERIT_SCRIPT version: 2 updated: 2003/03/01 23:50:42
1626 dnl -----------------
1627 dnl If we do not have a given script, look for it in the parent directory.
1628 AC_DEFUN([CF_INHERIT_SCRIPT],
1629 [
1630 test -f $1 || ( test -f ../$1 && cp ../$1 ./ )
1631 ])dnl
1632 dnl ---------------------------------------------------------------------------
1633 dnl CF_INTEL_COMPILER version: 4 updated: 2010/05/26 05:38:42
1634 dnl -----------------
1635 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1636 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1637 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1638 dnl
1639 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1640 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1641 dnl the wrappers for gcc and g++ warnings.
1642 dnl
1643 dnl $1 = GCC (default) or GXX
1644 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1645 dnl $3 = CFLAGS (default) or CXXFLAGS
1646 AC_DEFUN([CF_INTEL_COMPILER],[
1647 ifelse([$2],,INTEL_COMPILER,[$2])=no
1648
1649 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1650         case $host_os in
1651         linux*|gnu*)
1652                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1653                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1654                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1655                 AC_TRY_COMPILE([],[
1656 #ifdef __INTEL_COMPILER
1657 #else
1658 make an error
1659 #endif
1660 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1661 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
1662 ],[])
1663                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1664                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1665                 ;;
1666         esac
1667 fi
1668 ])dnl
1669 dnl ---------------------------------------------------------------------------
1670 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
1671 dnl ---------------
1672 dnl For the given system and compiler, find the compiler flags to pass to the
1673 dnl loader to use the "rpath" feature.
1674 AC_DEFUN([CF_LD_RPATH_OPT],
1675 [
1676 AC_REQUIRE([CF_CHECK_CACHE])
1677
1678 LD_RPATH_OPT=
1679 AC_MSG_CHECKING(for an rpath option)
1680 case $cf_cv_system_name in #(vi
1681 irix*) #(vi
1682         if test "$GCC" = yes; then
1683                 LD_RPATH_OPT="-Wl,-rpath,"
1684         else
1685                 LD_RPATH_OPT="-rpath "
1686         fi
1687         ;;
1688 linux*|gnu*|k*bsd*-gnu) #(vi
1689         LD_RPATH_OPT="-Wl,-rpath,"
1690         ;;
1691 openbsd[[2-9]].*|mirbsd*) #(vi
1692         LD_RPATH_OPT="-Wl,-rpath,"
1693         ;;
1694 dragonfly*|freebsd*) #(vi
1695         LD_RPATH_OPT="-rpath "
1696         ;;
1697 netbsd*) #(vi
1698         LD_RPATH_OPT="-Wl,-rpath,"
1699         ;;
1700 osf*|mls+*) #(vi
1701         LD_RPATH_OPT="-rpath "
1702         ;;
1703 solaris2*) #(vi
1704         LD_RPATH_OPT="-R"
1705         ;;
1706 *)
1707         ;;
1708 esac
1709 AC_MSG_RESULT($LD_RPATH_OPT)
1710
1711 case "x$LD_RPATH_OPT" in #(vi
1712 x-R*)
1713         AC_MSG_CHECKING(if we need a space after rpath option)
1714         cf_save_LIBS="$LIBS"
1715         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1716         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1717         LIBS="$cf_save_LIBS"
1718         AC_MSG_RESULT($cf_rpath_space)
1719         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1720         ;;
1721 esac
1722 ])dnl
1723 dnl ---------------------------------------------------------------------------
1724 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
1725 dnl ---------------
1726 dnl Construct a search-list of directories for a nonstandard library-file
1727 dnl
1728 dnl Parameters
1729 dnl     $1 = the variable to return as result
1730 dnl     $2 = the package name
1731 AC_DEFUN([CF_LIBRARY_PATH],
1732 [
1733 $1=
1734 cf_library_path_list=""
1735 if test -n "${LDFLAGS}${LIBS}" ; then
1736         for cf_library_path in $LDFLAGS $LIBS
1737         do
1738                 case $cf_library_path in #(vi
1739                 -L*)
1740                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1741                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1742                         cf_library_path_list="$cf_library_path_list [$]$1"
1743                         ;;
1744                 esac
1745         done
1746 fi
1747
1748 CF_SUBDIR_PATH($1,$2,lib)
1749
1750 $1="$cf_library_path_list [$]$1"
1751 ])dnl
1752 dnl ---------------------------------------------------------------------------
1753 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
1754 dnl ------------
1755 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
1756 dnl a monocase filesystem.
1757 AC_DEFUN([CF_MAKE_TAGS],[
1758 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
1759
1760 AC_CHECK_PROGS(CTAGS, exctags ctags)
1761 AC_CHECK_PROGS(ETAGS, exetags etags)
1762
1763 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
1764
1765 if test "$cf_cv_mixedcase" = yes ; then
1766         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
1767 else
1768         MAKE_UPPER_TAGS=no
1769 fi
1770
1771 if test "$MAKE_UPPER_TAGS" = yes ; then
1772         MAKE_UPPER_TAGS=
1773 else
1774         MAKE_UPPER_TAGS="#"
1775 fi
1776
1777 if test "$MAKE_LOWER_TAGS" = yes ; then
1778         MAKE_LOWER_TAGS=
1779 else
1780         MAKE_LOWER_TAGS="#"
1781 fi
1782
1783 AC_SUBST(CTAGS)
1784 AC_SUBST(ETAGS)
1785
1786 AC_SUBST(MAKE_UPPER_TAGS)
1787 AC_SUBST(MAKE_LOWER_TAGS)
1788 ])dnl
1789 dnl ---------------------------------------------------------------------------
1790 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
1791 dnl -----------
1792 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
1793 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
1794 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
1795 AC_DEFUN([CF_MATH_LIB],
1796 [
1797 AC_CACHE_CHECK(if -lm needed for math functions,
1798         cf_cv_need_libm,[
1799         AC_TRY_LINK([
1800         #include <stdio.h>
1801         #include <math.h>
1802         ],
1803         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
1804         [cf_cv_need_libm=no],
1805         [cf_cv_need_libm=yes])])
1806 if test "$cf_cv_need_libm" = yes
1807 then
1808 ifelse($1,,[
1809         CF_ADD_LIB(m)
1810 ],[$1=-lm])
1811 fi
1812 ])
1813 dnl ---------------------------------------------------------------------------
1814 dnl CF_MIN_GETCCHAR version: 3 updated: 2010/10/23 15:54:49
1815 dnl ---------------
1816 dnl CF_MIN_GETCCHAR
1817 dnl Check whether getcchar's return value counts the trailing null in a wchar_t
1818 dnl string, or not.  X/Open says it does, but Tru64 and Solaris do not do this.
1819 AC_DEFUN([CF_MIN_GETCCHAR],[
1820 AC_CACHE_CHECK(if getcchar counts trailing null,cf_cv_min_getcchar,[
1821 AC_TRY_RUN([
1822 #include <stdlib.h>
1823 #include <stdarg.h>
1824 #include <${cf_cv_ncurses_header:-curses.h}>
1825
1826 int main()
1827 {
1828         wchar_t data[2];
1829         cchar_t temp[2];
1830         int count;
1831         data[0] = L'\0';
1832     setcchar(temp, data, 0, 0, (void *)0);
1833         count = getcchar(temp, (wchar_t *)0, (attr_t *)0, (short *)0, (void *)0);
1834         ${cf_cv_main_return:-return}(count != 0);
1835 }],
1836         [cf_cv_min_getcchar=no],
1837         [cf_cv_min_getcchar=yes],
1838         [cf_cv_min_getcchar=yes])
1839 ])
1840 if test "$cf_cv_min_getcchar" = yes ; then
1841         AC_DEFINE(MIN_GETCCHAR,1)
1842 fi
1843 ])dnl
1844 dnl ---------------------------------------------------------------------------
1845 dnl CF_MIXEDCASE_FILENAMES version: 3 updated: 2003/09/20 17:07:55
1846 dnl ----------------------
1847 dnl Check if the file-system supports mixed-case filenames.  If we're able to
1848 dnl create a lowercase name and see it as uppercase, it doesn't support that.
1849 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
1850 [
1851 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
1852 if test "$cross_compiling" = yes ; then
1853         case $target_alias in #(vi
1854         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-mingw32*|*-uwin*) #(vi
1855                 cf_cv_mixedcase=no
1856                 ;;
1857         *)
1858                 cf_cv_mixedcase=yes
1859                 ;;
1860         esac
1861 else
1862         rm -f conftest CONFTEST
1863         echo test >conftest
1864         if test -f CONFTEST ; then
1865                 cf_cv_mixedcase=no
1866         else
1867                 cf_cv_mixedcase=yes
1868         fi
1869         rm -f conftest CONFTEST
1870 fi
1871 ])
1872 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES)
1873 ])dnl
1874 dnl ---------------------------------------------------------------------------
1875 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
1876 dnl ----------
1877 dnl Write a debug message to config.log, along with the line number in the
1878 dnl configure script.
1879 AC_DEFUN([CF_MSG_LOG],[
1880 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
1881 ])dnl
1882 dnl ---------------------------------------------------------------------------
1883 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
1884 dnl -------------------
1885 dnl Check if we can compile with ncurses' header file
1886 dnl $1 is the cache variable to set
1887 dnl $2 is the header-file to include
1888 dnl $3 is the root name (ncurses or ncursesw)
1889 AC_DEFUN([CF_NCURSES_CC_CHECK],[
1890         AC_TRY_COMPILE([
1891 ]ifelse($3,ncursesw,[
1892 #define _XOPEN_SOURCE_EXTENDED
1893 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
1894 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
1895 ])[
1896 #include <$2>],[
1897 #ifdef NCURSES_VERSION
1898 ]ifelse($3,ncursesw,[
1899 #ifndef WACS_BSSB
1900         make an error
1901 #endif
1902 ])[
1903 printf("%s\n", NCURSES_VERSION);
1904 #else
1905 #ifdef __NCURSES_H
1906 printf("old\n");
1907 #else
1908         make an error
1909 #endif
1910 #endif
1911         ]
1912         ,[$1=$2]
1913         ,[$1=no])
1914 ])dnl
1915 dnl ---------------------------------------------------------------------------
1916 dnl CF_NCURSES_CONFIG version: 9 updated: 2011/11/26 15:42:05
1917 dnl -----------------
1918 dnl Tie together the configure-script macros for ncurses.
1919 dnl Prefer the "-config" script from ncurses 6.x, to simplify analysis.
1920 dnl Allow that to be overridden using the $NCURSES_CONFIG environment variable.
1921 dnl
1922 dnl $1 is the root library name (default: "ncurses")
1923 AC_DEFUN([CF_NCURSES_CONFIG],
1924 [
1925 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
1926
1927 echo "Looking for ${cf_ncuconfig_root}-config"
1928
1929 CF_ACVERSION_CHECK(2.52,
1930         [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
1931         [AC_PATH_PROGS(NCURSES_CONFIG, ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
1932
1933 if test "$NCURSES_CONFIG" != none ; then
1934
1935 CPPFLAGS="$CPPFLAGS `$NCURSES_CONFIG --cflags`"
1936 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
1937
1938 # even with config script, some packages use no-override for curses.h
1939 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
1940
1941 dnl like CF_NCURSES_CPPFLAGS
1942 AC_DEFINE(NCURSES)
1943
1944 dnl like CF_NCURSES_LIBS
1945 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
1946 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
1947
1948 dnl like CF_NCURSES_VERSION
1949 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
1950
1951 else
1952
1953 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
1954 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
1955
1956 fi
1957 ])dnl
1958 dnl ---------------------------------------------------------------------------
1959 dnl CF_NCURSES_CPPFLAGS version: 20 updated: 2010/11/20 17:02:38
1960 dnl -------------------
1961 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
1962 dnl the CPPFLAGS variable so we can include its header.
1963 dnl
1964 dnl The header files may be installed as either curses.h, or ncurses.h (would
1965 dnl be obsolete, except that some packagers prefer this name to distinguish it
1966 dnl from a "native" curses implementation).  If not installed for overwrite,
1967 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
1968 dnl /usr/include/ncurses), but someone may have installed overwriting the
1969 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
1970 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
1971 dnl the header.
1972 dnl
1973 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
1974 dnl is already in the include-path, don't even bother with this, since we cannot
1975 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
1976 dnl
1977 dnl The optional parameter gives the root name of the library, in case it is
1978 dnl not installed as the default curses library.  That is how the
1979 dnl wide-character version of ncurses is installed.
1980 AC_DEFUN([CF_NCURSES_CPPFLAGS],
1981 [AC_REQUIRE([CF_WITH_CURSES_DIR])
1982
1983 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
1984 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
1985
1986 test -n "$cf_cv_curses_dir" && \
1987 test "$cf_cv_curses_dir" != "no" && { \
1988   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
1989 }
1990
1991 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
1992         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
1993         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
1994         for cf_header in $cf_header_list
1995         do
1996                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
1997                 test "$cf_cv_ncurses_h" != no && break
1998         done
1999 ])
2000
2001 CF_NCURSES_HEADER
2002 CF_TERM_HEADER
2003
2004 # some applications need this, but should check for NCURSES_VERSION
2005 AC_DEFINE(NCURSES)
2006
2007 CF_NCURSES_VERSION
2008 ])dnl
2009 dnl ---------------------------------------------------------------------------
2010 dnl CF_NCURSES_EXT_FUNCS version: 3 updated: 2010/11/13 19:43:23
2011 dnl --------------------
2012 dnl Since 2007/11/17, ncurses has defined NCURSES_EXT_FUNCS; earlier versions
2013 dnl may provide these functions.  Define the symbol if it is not defined, and
2014 dnl if it is valid.
2015 AC_DEFUN([CF_NCURSES_EXT_FUNCS],
2016 [
2017 AC_CACHE_CHECK(for ncurses extended functions,cf_cv_ncurses_ext_funcs,[
2018 AC_TRY_COMPILE([
2019 #include <${cf_cv_ncurses_header:-curses.h}>],
2020 [
2021 int x = NCURSES_EXT_FUNCS
2022 ],[cf_cv_ncurses_ext_funcs=defined],[
2023 AC_TRY_LINK([
2024 #include <${cf_cv_ncurses_header:-curses.h}>],
2025 [
2026         (void) assume_default_colors (0, 0);
2027         (void) curses_version ();
2028         (void) define_key (0, 0);
2029         (void) is_term_resized (0, 0);
2030         (void) key_defined (0);
2031         (void) keybound (0, 0);
2032         (void) keyok (0, 0);
2033         (void) resize_term (0, 0);
2034         (void) resizeterm (0, 0);
2035         (void) use_default_colors ();
2036         (void) use_extended_names (0);
2037         (void) wresize (0, 0, 0);],
2038         [cf_cv_ncurses_ext_funcs=yes],
2039         [cf_cv_ncurses_ext_funcs=no])
2040 ])
2041 ])
2042 test "$cf_cv_ncurses_ext_funcs" = yes && AC_DEFINE(NCURSES_EXT_FUNCS)
2043 ])dnl
2044 dnl ---------------------------------------------------------------------------
2045 dnl CF_NCURSES_HEADER version: 2 updated: 2008/03/23 14:48:54
2046 dnl -----------------
2047 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2048 dnl variations of ncurses' installs.
2049 dnl
2050 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2051 AC_DEFUN([CF_NCURSES_HEADER],[
2052
2053 if test "$cf_cv_ncurses_h" != no ; then
2054         cf_cv_ncurses_header=$cf_cv_ncurses_h
2055 else
2056
2057 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2058         test -n "$verbose" && echo
2059         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2060         test -n "$verbose" && echo search path $cf_search
2061         cf_save2_CPPFLAGS="$CPPFLAGS"
2062         for cf_incdir in $cf_search
2063         do
2064                 CF_ADD_INCDIR($cf_incdir)
2065                 for cf_header in \
2066                         ncurses.h \
2067                         curses.h
2068                 do
2069                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2070                         if test "$cf_cv_ncurses_h2" != no ; then
2071                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2072                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2073                                 break
2074                         fi
2075                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2076                 done
2077                 CPPFLAGS="$cf_save2_CPPFLAGS"
2078                 test "$cf_cv_ncurses_h2" != no && break
2079         done
2080         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2081         ])
2082
2083         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2084         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2085         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2086                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2087         fi
2088         CF_ADD_INCDIR($cf_1st_incdir)
2089
2090 fi
2091
2092 # Set definitions to allow ifdef'ing for ncurses.h
2093
2094 case $cf_cv_ncurses_header in # (vi
2095 *ncurses.h)
2096         AC_DEFINE(HAVE_NCURSES_H)
2097         ;;
2098 esac
2099
2100 case $cf_cv_ncurses_header in # (vi
2101 ncurses/curses.h|ncurses/ncurses.h)
2102         AC_DEFINE(HAVE_NCURSES_NCURSES_H)
2103         ;;
2104 ncursesw/curses.h|ncursesw/ncurses.h)
2105         AC_DEFINE(HAVE_NCURSESW_NCURSES_H)
2106         ;;
2107 esac
2108
2109 ])dnl
2110 dnl ---------------------------------------------------------------------------
2111 dnl CF_NCURSES_LIBS version: 16 updated: 2010/11/20 17:02:38
2112 dnl ---------------
2113 dnl Look for the ncurses library.  This is a little complicated on Linux,
2114 dnl because it may be linked with the gpm (general purpose mouse) library.
2115 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2116 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2117 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2118 dnl and the linker will record a dependency.
2119 dnl
2120 dnl The optional parameter gives the root name of the library, in case it is
2121 dnl not installed as the default curses library.  That is how the
2122 dnl wide-character version of ncurses is installed.
2123 AC_DEFUN([CF_NCURSES_LIBS],
2124 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2125
2126 cf_nculib_root=ifelse($1,,ncurses,$1)
2127         # This works, except for the special case where we find gpm, but
2128         # ncurses is in a nonstandard location via $LIBS, and we really want
2129         # to link gpm.
2130 cf_ncurses_LIBS=""
2131 cf_ncurses_SAVE="$LIBS"
2132 AC_CHECK_LIB(gpm,Gpm_Open,
2133         [AC_CHECK_LIB(gpm,initscr,
2134                 [LIBS="$cf_ncurses_SAVE"],
2135                 [cf_ncurses_LIBS="-lgpm"])])
2136
2137 case $host_os in #(vi
2138 freebsd*)
2139         # This is only necessary if you are linking against an obsolete
2140         # version of ncurses (but it should do no harm, since it's static).
2141         if test "$cf_nculib_root" = ncurses ; then
2142                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2143         fi
2144         ;;
2145 esac
2146
2147 CF_ADD_LIBS($cf_ncurses_LIBS)
2148
2149 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2150 then
2151         CF_ADD_LIBS(-l$cf_nculib_root)
2152 else
2153         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2154                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2155                 [initscr()],
2156                 initscr)
2157 fi
2158
2159 if test -n "$cf_ncurses_LIBS" ; then
2160         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2161         cf_ncurses_SAVE="$LIBS"
2162         for p in $cf_ncurses_LIBS ; do
2163                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2164                 if test "$q" != "$LIBS" ; then
2165                         LIBS="$q"
2166                 fi
2167         done
2168         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2169                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2170                 [AC_MSG_RESULT(yes)],
2171                 [AC_MSG_RESULT(no)
2172                  LIBS="$cf_ncurses_SAVE"])
2173 fi
2174
2175 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2176 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2177 ])dnl
2178 dnl ---------------------------------------------------------------------------
2179 dnl CF_NCURSES_VERSION version: 13 updated: 2010/10/23 15:54:49
2180 dnl ------------------
2181 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2182 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2183 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2184 AC_DEFUN([CF_NCURSES_VERSION],
2185 [
2186 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2187 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2188         cf_cv_ncurses_version=no
2189         cf_tempfile=out$$
2190         rm -f $cf_tempfile
2191         AC_TRY_RUN([
2192 #include <${cf_cv_ncurses_header:-curses.h}>
2193 #include <stdio.h>
2194 int main()
2195 {
2196         FILE *fp = fopen("$cf_tempfile", "w");
2197 #ifdef NCURSES_VERSION
2198 # ifdef NCURSES_VERSION_PATCH
2199         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2200 # else
2201         fprintf(fp, "%s\n", NCURSES_VERSION);
2202 # endif
2203 #else
2204 # ifdef __NCURSES_H
2205         fprintf(fp, "old\n");
2206 # else
2207         make an error
2208 # endif
2209 #endif
2210         ${cf_cv_main_return:-return}(0);
2211 }],[
2212         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2213
2214         # This will not work if the preprocessor splits the line after the
2215         # Autoconf token.  The 'unproto' program does that.
2216         cat > conftest.$ac_ext <<EOF
2217 #include <${cf_cv_ncurses_header:-curses.h}>
2218 #undef Autoconf
2219 #ifdef NCURSES_VERSION
2220 Autoconf NCURSES_VERSION
2221 #else
2222 #ifdef __NCURSES_H
2223 Autoconf "old"
2224 #endif
2225 ;
2226 #endif
2227 EOF
2228         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2229         AC_TRY_EVAL(cf_try)
2230         if test -f conftest.out ; then
2231                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2232                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2233                 rm -f conftest.out
2234         fi
2235 ])
2236         rm -f $cf_tempfile
2237 ])
2238 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES)
2239 ])dnl
2240 dnl ---------------------------------------------------------------------------
2241 dnl CF_NCURSES_WRAP_PREFIX version: 1 updated: 2009/03/28 16:08:10
2242 dnl ----------------------
2243 dnl Check for ncurses "wrap-prefix" used for public variables which have been
2244 dnl wrapped with a function to help with concurrency control.
2245 AC_DEFUN([CF_NCURSES_WRAP_PREFIX],
2246 [
2247 AC_MSG_CHECKING(for ncurses wrap-prefix)
2248 AC_ARG_WITH(ncurses-wrap-prefix,
2249         [  --with-ncurses-wrap-prefix naming-prefix for ncurses wrapped-variables],
2250         [NCURSES_WRAP_PREFIX=$withval],
2251         [NCURSES_WRAP_PREFIX=_nc_])
2252 AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
2253
2254 AC_SUBST(NCURSES_WRAP_PREFIX)
2255 ])
2256 dnl ---------------------------------------------------------------------------
2257 dnl CF_NETBSD_FORM_H version: 1 updated: 2011/01/15 14:59:18
2258 dnl ----------------
2259 dnl Check for NetBSD's form.h, which is incompatible with SVr4 and ncurses.
2260 dnl Some workarounds are needed in client programs to allow them to compile.
2261 AC_DEFUN([CF_NETBSD_FORM_H],[
2262 AC_CACHE_CHECK(for NetBSD form.h,cf_cv_netbsd_form_h,[
2263 AC_TRY_COMPILE([
2264 #include <${cf_cv_ncurses_header:-curses.h}>
2265 #include <form.h>
2266 ],[
2267         FORM *form;
2268         int y = current_field(form)->cursor_ypos;
2269         int x = current_field(form)->cursor_xpos;
2270 ],[cf_cv_netbsd_form_h=yes
2271 ],[cf_cv_netbsd_form_h=no])
2272 ])
2273
2274 test "$cf_cv_netbsd_form_h" = yes && AC_DEFINE(HAVE_NETBSD_FORM_H)
2275 ])dnl
2276 dnl ---------------------------------------------------------------------------
2277 dnl CF_NETBSD_MENU_H version: 1 updated: 2011/01/15 14:59:18
2278 dnl ----------------
2279 dnl Check for NetBSD's menu.h, which is incompatible with SVr4 and ncurses.
2280 dnl Some workarounds are needed in client programs to allow them to compile.
2281 AC_DEFUN([CF_NETBSD_MENU_H],[
2282 AC_CACHE_CHECK(for NetBSD menu.h,cf_cv_netbsd_menu_h,[
2283 AC_TRY_COMPILE([
2284 #include <${cf_cv_ncurses_header:-curses.h}>
2285 #include <menu.h>
2286 ],[
2287         MENU *menu;
2288         int y = menu->max_item_width;
2289 ],[cf_cv_netbsd_menu_h=yes
2290 ],[cf_cv_netbsd_menu_h=no])
2291 ])
2292
2293 test "$cf_cv_netbsd_menu_h" = yes && AC_DEFINE(HAVE_NETBSD_MENU_H)
2294 ])dnl
2295 dnl ---------------------------------------------------------------------------
2296 dnl CF_NO_LEAKS_OPTION version: 4 updated: 2006/12/16 14:24:05
2297 dnl ------------------
2298 dnl see CF_WITH_NO_LEAKS
2299 AC_DEFUN([CF_NO_LEAKS_OPTION],[
2300 AC_MSG_CHECKING(if you want to use $1 for testing)
2301 AC_ARG_WITH($1,
2302         [$2],
2303         [AC_DEFINE($3)ifelse([$4],,[
2304          $4
2305 ])
2306         : ${with_cflags:=-g}
2307         : ${with_no_leaks:=yes}
2308          with_$1=yes],
2309         [with_$1=])
2310 AC_MSG_RESULT(${with_$1:-no})
2311
2312 case .$with_cflags in #(vi
2313 .*-g*)
2314         case .$CFLAGS in #(vi
2315         .*-g*) #(vi
2316                 ;;
2317         *)
2318                 CF_ADD_CFLAGS([-g])
2319                 ;;
2320         esac
2321         ;;
2322 esac
2323 ])dnl
2324 dnl ---------------------------------------------------------------------------
2325 dnl CF_PATH_SYNTAX version: 13 updated: 2010/05/26 05:38:42
2326 dnl --------------
2327 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2328 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2329 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2330 dnl delayed evaluation of those symbols.
2331 AC_DEFUN([CF_PATH_SYNTAX],[
2332 if test "x$prefix" != xNONE; then
2333   cf_path_syntax="$prefix"
2334 else
2335   cf_path_syntax="$ac_default_prefix"
2336 fi
2337
2338 case ".[$]$1" in #(vi
2339 .\[$]\(*\)*|.\'*\'*) #(vi
2340   ;;
2341 ..|./*|.\\*) #(vi
2342   ;;
2343 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
2344   ;;
2345 .\[$]{*prefix}*) #(vi
2346   eval $1="[$]$1"
2347   case ".[$]$1" in #(vi
2348   .NONE/*)
2349     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2350     ;;
2351   esac
2352   ;; #(vi
2353 .no|.NONE/*)
2354   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2355   ;;
2356 *)
2357   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2358   ;;
2359 esac
2360 ])dnl
2361 dnl ---------------------------------------------------------------------------
2362 dnl CF_PDCURSES_X11 version: 12 updated: 2011/11/26 15:42:05
2363 dnl ---------------
2364 dnl Configure for PDCurses' X11 library
2365 AC_DEFUN([CF_PDCURSES_X11],[
2366 AC_REQUIRE([CF_X_ATHENA])
2367
2368 CF_ACVERSION_CHECK(2.52,
2369         [AC_CHECK_TOOLS(XCURSES_CONFIG, xcurses-config, none)],
2370         [AC_PATH_PROGS(XCURSES_CONFIG, xcurses-config, none)])
2371
2372 if test "$XCURSES_CONFIG" != none ; then
2373
2374 CPPFLAGS="$CPPFLAGS `$XCURSES_CONFIG --cflags`"
2375 CF_ADD_LIBS(`$XCURSES_CONFIG --libs`)
2376
2377 cf_cv_lib_XCurses=yes
2378
2379 else
2380
2381 LDFLAGS="$LDFLAGS $X_LIBS"
2382 CF_CHECK_CFLAGS($X_CFLAGS)
2383 AC_CHECK_LIB(X11,XOpenDisplay,
2384         [CF_ADD_LIBS(-lX11)],,
2385         [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])
2386 AC_CACHE_CHECK(for XCurses library,cf_cv_lib_XCurses,[
2387 CF_ADD_LIBS(-lXCurses)
2388 AC_TRY_LINK([
2389 #include <xcurses.h>
2390 char *XCursesProgramName = "test";
2391 ],[XCursesExit();],
2392 [cf_cv_lib_XCurses=yes],
2393 [cf_cv_lib_XCurses=no])
2394 ])
2395
2396 fi
2397
2398 if test $cf_cv_lib_XCurses = yes ; then
2399         AC_DEFINE(UNIX)
2400         AC_DEFINE(XCURSES)
2401         AC_CHECK_HEADER(xcurses.h, AC_DEFINE(HAVE_XCURSES))
2402 else
2403         AC_MSG_ERROR(Cannot link with XCurses)
2404 fi
2405 ])dnl
2406 dnl ---------------------------------------------------------------------------
2407 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
2408 dnl -------------
2409 dnl Check for the package-config program, unless disabled by command-line.
2410 AC_DEFUN([CF_PKG_CONFIG],
2411 [
2412 AC_MSG_CHECKING(if you want to use pkg-config)
2413 AC_ARG_WITH(pkg-config,
2414         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2415         [cf_pkg_config=$withval],
2416         [cf_pkg_config=yes])
2417 AC_MSG_RESULT($cf_pkg_config)
2418
2419 case $cf_pkg_config in #(vi
2420 no) #(vi
2421         PKG_CONFIG=none
2422         ;;
2423 yes) #(vi
2424         CF_ACVERSION_CHECK(2.52,
2425                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2426                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2427         ;;
2428 *)
2429         PKG_CONFIG=$withval
2430         ;;
2431 esac
2432
2433 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2434 if test "$PKG_CONFIG" != none ; then
2435         CF_PATH_SYNTAX(PKG_CONFIG)
2436 fi
2437
2438 AC_SUBST(PKG_CONFIG)
2439 ])dnl
2440 dnl ---------------------------------------------------------------------------
2441 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
2442 dnl -----------------
2443 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2444 dnl
2445 dnl     POSIX.1-1990                            _POSIX_SOURCE
2446 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2447 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2448 dnl             Bindings Option
2449 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2450 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2451 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2452 dnl
2453 dnl Parameters:
2454 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2455 AC_DEFUN([CF_POSIX_C_SOURCE],
2456 [
2457 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2458
2459 cf_save_CFLAGS="$CFLAGS"
2460 cf_save_CPPFLAGS="$CPPFLAGS"
2461
2462 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2463 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2464
2465 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2466         CF_MSG_LOG(if the symbol is already defined go no further)
2467         AC_TRY_COMPILE([#include <sys/types.h>],[
2468 #ifndef _POSIX_C_SOURCE
2469 make an error
2470 #endif],
2471         [cf_cv_posix_c_source=no],
2472         [cf_want_posix_source=no
2473          case .$cf_POSIX_C_SOURCE in #(vi
2474          .[[12]]??*) #(vi
2475                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2476                 ;;
2477          .2) #(vi
2478                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2479                 cf_want_posix_source=yes
2480                 ;;
2481          .*)
2482                 cf_want_posix_source=yes
2483                 ;;
2484          esac
2485          if test "$cf_want_posix_source" = yes ; then
2486                 AC_TRY_COMPILE([#include <sys/types.h>],[
2487 #ifdef _POSIX_SOURCE
2488 make an error
2489 #endif],[],
2490                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2491          fi
2492          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2493          CFLAGS="$cf_trim_CFLAGS"
2494          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
2495          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2496          AC_TRY_COMPILE([#include <sys/types.h>],[
2497 #ifndef _POSIX_C_SOURCE
2498 make an error
2499 #endif],,
2500          [cf_cv_posix_c_source=no])
2501          CFLAGS="$cf_save_CFLAGS"
2502          CPPFLAGS="$cf_save_CPPFLAGS"
2503         ])
2504 ])
2505
2506 if test "$cf_cv_posix_c_source" != no ; then
2507         CFLAGS="$cf_trim_CFLAGS"
2508         CPPFLAGS="$cf_trim_CPPFLAGS"
2509         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2510 fi
2511
2512 ])dnl
2513 dnl ---------------------------------------------------------------------------
2514 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
2515 dnl ------------
2516 dnl Append definitions and rules for the given programs to the subdirectory
2517 dnl Makefiles, and the recursion rule for the top-level Makefile.
2518 dnl
2519 dnl parameters
2520 dnl     $1 = script to run
2521 dnl     $2 = list of subdirectories
2522 dnl
2523 dnl variables
2524 dnl     $AWK
2525 AC_DEFUN([CF_PRG_RULES],
2526 [
2527 for cf_dir in $2
2528 do
2529         if test ! -d $srcdir/$cf_dir; then
2530                 continue
2531         elif test -f $srcdir/$cf_dir/programs; then
2532                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
2533         fi
2534 done
2535
2536 ])dnl
2537 dnl ---------------------------------------------------------------------------
2538 dnl CF_PROG_CC_U_D version: 1 updated: 2005/07/14 16:59:30
2539 dnl --------------
2540 dnl Check if C (preprocessor) -U and -D options are processed in the order
2541 dnl given rather than by type of option.  Some compilers insist on apply all
2542 dnl of the -U options after all of the -D options.  Others allow mixing them,
2543 dnl and may predefine symbols that conflict with those we define.
2544 AC_DEFUN([CF_PROG_CC_U_D],
2545 [
2546 AC_CACHE_CHECK(if $CC -U and -D options work together,cf_cv_cc_u_d_options,[
2547         cf_save_CPPFLAGS="$CPPFLAGS"
2548         CPPFLAGS="-UU_D_OPTIONS -DU_D_OPTIONS -DD_U_OPTIONS -UD_U_OPTIONS"
2549         AC_TRY_COMPILE([],[
2550 #ifndef U_D_OPTIONS
2551 make an undefined-error
2552 #endif
2553 #ifdef  D_U_OPTIONS
2554 make a defined-error
2555 #endif
2556         ],[
2557         cf_cv_cc_u_d_options=yes],[
2558         cf_cv_cc_u_d_options=no])
2559         CPPFLAGS="$cf_save_CPPFLAGS"
2560 ])
2561 ])dnl
2562 dnl ---------------------------------------------------------------------------
2563 dnl CF_PROG_INSTALL version: 5 updated: 2002/12/21 22:46:07
2564 dnl ---------------
2565 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
2566 dnl misc/tabset install won't work properly.  Usually this happens only when
2567 dnl using the fallback mkinstalldirs script
2568 AC_DEFUN([CF_PROG_INSTALL],
2569 [AC_PROG_INSTALL
2570 case $INSTALL in
2571 /*)
2572   ;;
2573 *)
2574   CF_DIRNAME(cf_dir,$INSTALL)
2575   test -z "$cf_dir" && cf_dir=.
2576   INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
2577   ;;
2578 esac
2579 ])dnl
2580 dnl ---------------------------------------------------------------------------
2581 dnl CF_PROG_LINT version: 2 updated: 2009/08/12 04:43:14
2582 dnl ------------
2583 AC_DEFUN([CF_PROG_LINT],
2584 [
2585 AC_CHECK_PROGS(LINT, tdlint lint alint splint lclint)
2586 AC_SUBST(LINT_OPTS)
2587 ])dnl
2588 dnl ---------------------------------------------------------------------------
2589 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
2590 dnl ----------------
2591 dnl Remove all -U and -D options that refer to the given symbol from a list
2592 dnl of C compiler options.  This works around the problem that not all
2593 dnl compilers process -U and -D options from left-to-right, so a -U option
2594 dnl cannot be used to cancel the effect of a preceding -D option.
2595 dnl
2596 dnl $1 = target (which could be the same as the source variable)
2597 dnl $2 = source (including '$')
2598 dnl $3 = symbol to remove
2599 define([CF_REMOVE_DEFINE],
2600 [
2601 $1=`echo "$2" | \
2602         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
2603                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
2604 ])dnl
2605 dnl ---------------------------------------------------------------------------
2606 dnl CF_RPATH_HACK version: 9 updated: 2011/02/13 13:31:33
2607 dnl -------------
2608 AC_DEFUN([CF_RPATH_HACK],
2609 [
2610 AC_REQUIRE([CF_LD_RPATH_OPT])
2611 AC_MSG_CHECKING(for updated LDFLAGS)
2612 if test -n "$LD_RPATH_OPT" ; then
2613         AC_MSG_RESULT(maybe)
2614
2615         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
2616         cf_rpath_list="/usr/lib /lib"
2617         if test "$cf_ldd_prog" != no
2618         then
2619                 cf_rpath_oops=
2620
2621 AC_TRY_LINK([#include <stdio.h>],
2622                 [printf("Hello");],
2623                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort -u`
2624                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort -u`])
2625
2626                 # If we passed the link-test, but get a "not found" on a given library,
2627                 # this could be due to inept reconfiguration of gcc to make it only
2628                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
2629                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
2630                 # /usr/local libraries.
2631                 if test -n "$cf_rpath_oops"
2632                 then
2633                         for cf_rpath_src in $cf_rpath_oops
2634                         do
2635                                 for cf_rpath_dir in \
2636                                         /usr/local \
2637                                         /usr/pkg \
2638                                         /opt/sfw
2639                                 do
2640                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
2641                                         then
2642                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
2643                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
2644                                                 break
2645                                         fi
2646                                 done
2647                         done
2648                 fi
2649         fi
2650
2651         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
2652
2653         CF_RPATH_HACK_2(LDFLAGS)
2654         CF_RPATH_HACK_2(LIBS)
2655
2656         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
2657 fi
2658 AC_SUBST(EXTRA_LDFLAGS)
2659 ])dnl
2660 dnl ---------------------------------------------------------------------------
2661 dnl CF_RPATH_HACK_2 version: 6 updated: 2010/04/17 16:31:24
2662 dnl ---------------
2663 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
2664 dnl EXTRA_LDFLAGS for each -L option found.
2665 dnl
2666 dnl $cf_rpath_list contains a list of directories to ignore.
2667 dnl
2668 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
2669 dnl      but LIBS often has misplaced -L options.
2670 AC_DEFUN([CF_RPATH_HACK_2],
2671 [
2672 CF_VERBOSE(...checking $1 [$]$1)
2673
2674 cf_rpath_dst=
2675 for cf_rpath_src in [$]$1
2676 do
2677         case $cf_rpath_src in #(vi
2678         -L*) #(vi
2679
2680                 # check if this refers to a directory which we will ignore
2681                 cf_rpath_skip=no
2682                 if test -n "$cf_rpath_list"
2683                 then
2684                         for cf_rpath_item in $cf_rpath_list
2685                         do
2686                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
2687                                 then
2688                                         cf_rpath_skip=yes
2689                                         break
2690                                 fi
2691                         done
2692                 fi
2693
2694                 if test "$cf_rpath_skip" = no
2695                 then
2696                         # transform the option
2697                         if test "$LD_RPATH_OPT" = "-R " ; then
2698                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
2699                         else
2700                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
2701                         fi
2702
2703                         # if we have not already added this, add it now
2704                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
2705                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
2706                         then
2707                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
2708                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
2709                         fi
2710                 fi
2711                 ;;
2712         esac
2713         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
2714 done
2715 $1=$cf_rpath_dst
2716
2717 CF_VERBOSE(...checked $1 [$]$1)
2718 AC_SUBST(EXTRA_LDFLAGS)
2719 ])dnl
2720 dnl ---------------------------------------------------------------------------
2721 dnl CF_SIG_ATOMIC_T version: 2 updated: 2005/09/18 17:27:12
2722 dnl ---------------
2723 dnl signal handler, but there are some gcc depedencies in that recommendation.
2724 dnl Try anyway.
2725 AC_DEFUN([CF_SIG_ATOMIC_T],
2726 [
2727 AC_MSG_CHECKING(for signal global datatype)
2728 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
2729         for cf_type in \
2730                 "volatile sig_atomic_t" \
2731                 "sig_atomic_t" \
2732                 "int"
2733         do
2734         AC_TRY_COMPILE([
2735 #include <sys/types.h>
2736 #include <signal.h>
2737 #include <stdio.h>
2738
2739 extern $cf_type x;
2740 $cf_type x;
2741 static void handler(int sig)
2742 {
2743         x = 5;
2744 }],
2745                 [signal(SIGINT, handler);
2746                  x = 1],
2747                 [cf_cv_sig_atomic_t=$cf_type],
2748                 [cf_cv_sig_atomic_t=no])
2749                 test "$cf_cv_sig_atomic_t" != no && break
2750         done
2751         ])
2752 AC_MSG_RESULT($cf_cv_sig_atomic_t)
2753 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t)
2754 ])dnl
2755 dnl ---------------------------------------------------------------------------
2756 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
2757 dnl --------------
2758 dnl Construct a search-list for a nonstandard header/lib-file
2759 dnl     $1 = the variable to return as result
2760 dnl     $2 = the package name
2761 dnl     $3 = the subdirectory, e.g., bin, include or lib
2762 AC_DEFUN([CF_SUBDIR_PATH],
2763 [
2764 $1=
2765
2766 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
2767 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
2768 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
2769 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
2770 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
2771 ])dnl
2772 dnl ---------------------------------------------------------------------------
2773 dnl CF_SYS_TIME_SELECT version: 4 updated: 2000/10/04 09:18:40
2774 dnl ------------------
2775 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
2776 dnl older SCO configurations.
2777 AC_DEFUN([CF_SYS_TIME_SELECT],
2778 [
2779 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
2780 AC_CACHE_VAL(cf_cv_sys_time_select,[
2781 AC_TRY_COMPILE([
2782 #include <sys/types.h>
2783 #ifdef HAVE_SYS_TIME_H
2784 #include <sys/time.h>
2785 #endif
2786 #ifdef HAVE_SYS_SELECT_H
2787 #include <sys/select.h>
2788 #endif
2789 ],[],[cf_cv_sys_time_select=yes],
2790      [cf_cv_sys_time_select=no])
2791      ])
2792 AC_MSG_RESULT($cf_cv_sys_time_select)
2793 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT)
2794 ])dnl
2795 dnl ---------------------------------------------------------------------------
2796 dnl CF_TERM_HEADER version: 2 updated: 2010/10/23 15:54:49
2797 dnl --------------
2798 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
2799 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
2800 dnl but some packagers change this, breaking various applications.
2801 AC_DEFUN([CF_TERM_HEADER],[
2802 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
2803 case ${cf_cv_ncurses_header} in #(vi
2804 */ncurses.h|*/ncursesw.h) #(vi
2805         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
2806         ;;
2807 *)
2808         cf_term_header=term.h
2809         ;;
2810 esac
2811
2812 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
2813 do
2814 AC_TRY_COMPILE([#include <stdio.h>
2815 #include <${cf_cv_ncurses_header:-curses.h}>
2816 #include <$cf_test>
2817 ],[int x = auto_left_margin],[
2818         cf_cv_term_header="$cf_test"],[
2819         cf_cv_term_header=unknown
2820         ])
2821         test "$cf_cv_term_header" != unknown && break
2822 done
2823 ])
2824
2825 # Set definitions to allow ifdef'ing to accommodate subdirectories
2826
2827 case $cf_cv_term_header in # (vi
2828 *term.h)
2829         AC_DEFINE(HAVE_TERM_H)
2830         ;;
2831 esac
2832
2833 case $cf_cv_term_header in # (vi
2834 ncurses/term.h) #(vi
2835         AC_DEFINE(HAVE_NCURSES_TERM_H)
2836         ;;
2837 ncursesw/term.h)
2838         AC_DEFINE(HAVE_NCURSESW_TERM_H)
2839         ;;
2840 esac
2841 ])dnl
2842 dnl ---------------------------------------------------------------------------
2843 dnl CF_TOP_BUILDDIR version: 1 updated: 2006/10/15 16:33:23
2844 dnl ---------------
2845 dnl Define a top_builddir symbol, for applications that need an absolute path.
2846 AC_DEFUN([CF_TOP_BUILDDIR],
2847 [
2848 top_builddir=`pwd`
2849 AC_SUBST(top_builddir)
2850 ])dnl
2851 dnl ---------------------------------------------------------------------------
2852 dnl CF_TPUTS_PROTO version: 2 updated: 2011/04/23 19:25:50
2853 dnl --------------
2854 dnl Check for type of function-pointer passed to tputs.  Some old
2855 dnl implementations used functions that had different prototypes, making it
2856 dnl hard to compile portable programs using tputs.
2857 AC_DEFUN([CF_TPUTS_PROTO],[
2858 CF_CURSES_FUNCS(tputs)
2859 if test x$cf_cv_func_tputs = xyes
2860 then
2861         cf_done=no
2862         for cf_arg in int char
2863         do
2864                 for cf_ret in int void
2865                 do
2866                         if test $cf_ret = void
2867                         then
2868                                 cf_return="/* nothing */"
2869                         else
2870                                 cf_return="return value"
2871                         fi
2872                         AC_TRY_COMPILE([
2873 #include <${cf_cv_ncurses_header:-curses.h}>
2874 #include <$cf_cv_term_header>
2875
2876 static $cf_ret outc($cf_arg value) { $cf_return; }
2877 ],[
2878         tputs("hello", 0, outc);
2879         ${cf_cv_main_return:-return}(0);
2880 ],[
2881                 CF_VERBOSE([prototype $cf_ret func($cf_arg value)])
2882                 cat >>confdefs.h <<EOF
2883 #define TPUTS_ARG               $cf_arg
2884 #define TPUTS_PROTO(func,value) $cf_ret func(TPUTS_ARG value)
2885 #define TPUTS_RETURN(value)     $cf_return
2886 EOF
2887                 cf_done=yes
2888                 break
2889 ])
2890                 done
2891                 test $cf_done = yes && break
2892         done
2893 fi
2894 ])dnl
2895 dnl ---------------------------------------------------------------------------
2896 dnl CF_TRY_PKG_CONFIG version: 4 updated: 2010/06/14 17:42:30
2897 dnl -----------------
2898 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
2899 dnl available in that form.
2900 dnl
2901 dnl $1 = package name
2902 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
2903 dnl $3 = logic to use if pkg-config does not have the package
2904 AC_DEFUN([CF_TRY_PKG_CONFIG],[
2905 AC_REQUIRE([CF_PKG_CONFIG])
2906
2907 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists $1; then
2908         CF_VERBOSE(found package $1)
2909         cf_pkgconfig_incs="`$PKG_CONFIG --cflags $1 2>/dev/null`"
2910         cf_pkgconfig_libs="`$PKG_CONFIG --libs   $1 2>/dev/null`"
2911         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
2912         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
2913         CF_ADD_CFLAGS($cf_pkgconfig_incs)
2914         CF_ADD_LIBS($cf_pkgconfig_libs)
2915         ifelse([$2],,:,[$2])
2916 else
2917         ifelse([$3],,:,[$3])
2918 fi
2919 ])
2920 dnl ---------------------------------------------------------------------------
2921 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
2922 dnl -------------------
2923 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
2924 dnl can define it successfully.
2925 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
2926 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
2927         AC_TRY_COMPILE([
2928 #include <stdlib.h>
2929 #include <string.h>
2930 #include <sys/types.h>
2931 ],[
2932 #ifndef _XOPEN_SOURCE
2933 make an error
2934 #endif],
2935         [cf_cv_xopen_source=no],
2936         [cf_save="$CPPFLAGS"
2937          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
2938          AC_TRY_COMPILE([
2939 #include <stdlib.h>
2940 #include <string.h>
2941 #include <sys/types.h>
2942 ],[
2943 #ifdef _XOPEN_SOURCE
2944 make an error
2945 #endif],
2946         [cf_cv_xopen_source=no],
2947         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
2948         CPPFLAGS="$cf_save"
2949         ])
2950 ])
2951
2952 if test "$cf_cv_xopen_source" != no ; then
2953         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
2954         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
2955         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
2956         CF_ADD_CFLAGS($cf_temp_xopen_source)
2957 fi
2958 ])
2959 dnl ---------------------------------------------------------------------------
2960 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
2961 dnl --------
2962 dnl Make an uppercase version of a variable
2963 dnl $1=uppercase($2)
2964 AC_DEFUN([CF_UPPER],
2965 [
2966 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
2967 ])dnl
2968 dnl ---------------------------------------------------------------------------
2969 dnl CF_UTF8_LIB version: 7 updated: 2010/06/20 09:24:28
2970 dnl -----------
2971 dnl Check for multibyte support, and if not found, utf8 compatibility library
2972 AC_DEFUN([CF_UTF8_LIB],
2973 [
2974 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
2975         cf_save_LIBS="$LIBS"
2976         AC_TRY_LINK([
2977 #include <stdlib.h>],[putwc(0,0);],
2978         [cf_cv_utf8_lib=yes],
2979         [CF_FIND_LINKAGE([
2980 #include <libutf8.h>],[putwc(0,0);],utf8,
2981                 [cf_cv_utf8_lib=add-on],
2982                 [cf_cv_utf8_lib=no])
2983 ])])
2984
2985 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
2986 # ncurses/ncursesw:
2987 if test "$cf_cv_utf8_lib" = "add-on" ; then
2988         AC_DEFINE(HAVE_LIBUTF8_H)
2989         CF_ADD_INCDIR($cf_cv_header_path_utf8)
2990         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
2991         CF_ADD_LIBS($cf_cv_library_file_utf8)
2992 fi
2993 ])dnl
2994 dnl ---------------------------------------------------------------------------
2995 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
2996 dnl ----------
2997 dnl Use AC_VERBOSE w/o the warnings
2998 AC_DEFUN([CF_VERBOSE],
2999 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
3000 CF_MSG_LOG([$1])
3001 ])dnl
3002 dnl ---------------------------------------------------------------------------
3003 dnl CF_WCHAR_TYPE version: 3 updated: 2010/05/26 16:44:57
3004 dnl -------------
3005 dnl Check if type wide-character type $1 is declared, and if so, which header
3006 dnl file is needed.  The second parameter is used to set a shell variable when
3007 dnl the type is not found.  The first parameter sets a shell variable for the
3008 dnl opposite sense.
3009 AC_DEFUN([CF_WCHAR_TYPE],
3010 [
3011 # This is needed on Tru64 5.0 to declare $1
3012 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
3013 AC_TRY_COMPILE([
3014 #include <stdlib.h>
3015 #include <stdarg.h>
3016 #include <stdio.h>
3017 #ifdef HAVE_LIBUTF8_H
3018 #include <libutf8.h>
3019 #endif],
3020         [$1 state],
3021         [cf_cv_$1=no],
3022         [AC_TRY_COMPILE([
3023 #include <stdlib.h>
3024 #include <stdarg.h>
3025 #include <stdio.h>
3026 #include <wchar.h>
3027 #ifdef HAVE_LIBUTF8_H
3028 #include <libutf8.h>
3029 #endif],
3030         [$1 value],
3031         [cf_cv_$1=yes],
3032         [cf_cv_$1=unknown])])])
3033
3034 if test "$cf_cv_$1" = yes ; then
3035         AC_DEFINE(NEED_WCHAR_H)
3036         NEED_WCHAR_H=1
3037 fi
3038
3039 ifelse([$2],,,[
3040 # if we do not find $1 in either place, use substitution to provide a fallback.
3041 if test "$cf_cv_$1" = unknown ; then
3042         $2=1
3043 fi
3044 ])
3045 ifelse($3,,,[
3046 # if we find $1 in either place, use substitution to provide a fallback.
3047 if test "$cf_cv_$1" != unknown ; then
3048         $3=1
3049 fi
3050 ])
3051 ])dnl
3052 dnl ---------------------------------------------------------------------------
3053 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3054 dnl ------------------
3055 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3056 dnl libraries.
3057 AC_DEFUN([CF_WITH_CURSES_DIR],[
3058
3059 AC_MSG_CHECKING(for specific curses-directory)
3060 AC_ARG_WITH(curses-dir,
3061         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3062         [cf_cv_curses_dir=$withval],
3063         [cf_cv_curses_dir=no])
3064 AC_MSG_RESULT($cf_cv_curses_dir)
3065
3066 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3067 then
3068         CF_PATH_SYNTAX(withval)
3069         if test -d "$cf_cv_curses_dir"
3070         then
3071                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3072                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3073         fi
3074 fi
3075 ])dnl
3076 dnl ---------------------------------------------------------------------------
3077 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
3078 dnl ----------------
3079 dnl Configure-option for dbmalloc.  The optional parameter is used to override
3080 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
3081 AC_DEFUN([CF_WITH_DBMALLOC],[
3082 CF_NO_LEAKS_OPTION(dbmalloc,
3083         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
3084         [USE_DBMALLOC])
3085
3086 if test "$with_dbmalloc" = yes ; then
3087         AC_CHECK_HEADER(dbmalloc.h,
3088                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
3089 fi
3090 ])dnl
3091 dnl ---------------------------------------------------------------------------
3092 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
3093 dnl ---------------
3094 dnl Configure-option for dmalloc.  The optional parameter is used to override
3095 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
3096 AC_DEFUN([CF_WITH_DMALLOC],[
3097 CF_NO_LEAKS_OPTION(dmalloc,
3098         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
3099         [USE_DMALLOC])
3100
3101 if test "$with_dmalloc" = yes ; then
3102         AC_CHECK_HEADER(dmalloc.h,
3103                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
3104 fi
3105 ])dnl
3106 dnl ---------------------------------------------------------------------------
3107 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
3108 dnl ----------------
3109 AC_DEFUN([CF_WITH_VALGRIND],[
3110 CF_NO_LEAKS_OPTION(valgrind,
3111         [  --with-valgrind         test: use valgrind],
3112         [USE_VALGRIND])
3113 ])dnl
3114 dnl ---------------------------------------------------------------------------
3115 dnl CF_XOPEN_CURSES version: 11 updated: 2011/01/18 18:15:30
3116 dnl ---------------
3117 dnl Test if we should define X/Open source for curses, needed on Digital Unix
3118 dnl 4.x, to see the extended functions, but breaks on IRIX 6.x.
3119 dnl
3120 dnl The getbegyx() check is needed for HPUX, which omits legacy macros such
3121 dnl as getbegy().  The latter is better design, but the former is standard.
3122 AC_DEFUN([CF_XOPEN_CURSES],
3123 [
3124 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
3125 AC_CACHE_CHECK(if we must define _XOPEN_SOURCE_EXTENDED,cf_cv_need_xopen_extension,[
3126 AC_TRY_LINK([
3127 #include <stdlib.h>
3128 #include <${cf_cv_ncurses_header:-curses.h}>],[
3129 #if defined(NCURSES_VERSION_PATCH)
3130 #if (NCURSES_VERSION_PATCH < 20100501) && (NCURSES_VERSION_PATCH >= 20100403)
3131         make an error
3132 #endif
3133 #endif
3134         long x = winnstr(stdscr, "", 0);
3135         int x1, y1;
3136         getbegyx(stdscr, y1, x1)],
3137         [cf_cv_need_xopen_extension=no],
3138         [AC_TRY_LINK([
3139 #define _XOPEN_SOURCE_EXTENDED
3140 #include <stdlib.h>
3141 #include <${cf_cv_ncurses_header:-curses.h}>],[
3142 #ifdef NCURSES_VERSION
3143         cchar_t check;
3144         int check2 = curs_set((int)sizeof(check));
3145 #endif
3146         long x = winnstr(stdscr, "", 0);
3147         int x1, y1;
3148         getbegyx(stdscr, y1, x1)],
3149         [cf_cv_need_xopen_extension=yes],
3150         [cf_cv_need_xopen_extension=unknown])])])
3151 test $cf_cv_need_xopen_extension = yes && CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED"
3152 ])dnl
3153 dnl ---------------------------------------------------------------------------
3154 dnl CF_XOPEN_SOURCE version: 41 updated: 2011/12/10 18:58:47
3155 dnl ---------------
3156 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
3157 dnl or adapt to the vendor's definitions to get equivalent functionality,
3158 dnl without losing the common non-POSIX features.
3159 dnl
3160 dnl Parameters:
3161 dnl     $1 is the nominal value for _XOPEN_SOURCE
3162 dnl     $2 is the nominal value for _POSIX_C_SOURCE
3163 AC_DEFUN([CF_XOPEN_SOURCE],[
3164
3165 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
3166 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
3167 cf_xopen_source=
3168
3169 case $host_os in #(vi
3170 aix[[4-7]]*) #(vi
3171         cf_xopen_source="-D_ALL_SOURCE"
3172         ;;
3173 cygwin) #(vi
3174         cf_XOPEN_SOURCE=600
3175         ;;
3176 darwin[[0-8]].*) #(vi
3177         cf_xopen_source="-D_APPLE_C_SOURCE"
3178         ;;
3179 darwin*) #(vi
3180         cf_xopen_source="-D_DARWIN_C_SOURCE"
3181         ;;
3182 freebsd*|dragonfly*) #(vi
3183         # 5.x headers associate
3184         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
3185         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
3186         cf_POSIX_C_SOURCE=200112L
3187         cf_XOPEN_SOURCE=600
3188         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3189         ;;
3190 hpux11*) #(vi
3191         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
3192         ;;
3193 hpux*) #(vi
3194         cf_xopen_source="-D_HPUX_SOURCE"
3195         ;;
3196 irix[[56]].*) #(vi
3197         cf_xopen_source="-D_SGI_SOURCE"
3198         cf_XOPEN_SOURCE=
3199         ;;
3200 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
3201         CF_GNU_SOURCE
3202         ;;
3203 mirbsd*) #(vi
3204         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
3205         cf_XOPEN_SOURCE=
3206         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3207         ;;
3208 netbsd*) #(vi
3209         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
3210         ;;
3211 openbsd[[4-9]]*) #(vi
3212         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
3213         cf_XOPEN_SOURCE=600
3214         ;;
3215 openbsd*) #(vi
3216         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
3217         ;;
3218 osf[[45]]*) #(vi
3219         cf_xopen_source="-D_OSF_SOURCE"
3220         ;;
3221 nto-qnx*) #(vi
3222         cf_xopen_source="-D_QNX_SOURCE"
3223         ;;
3224 sco*) #(vi
3225         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
3226         ;;
3227 solaris2.*) #(vi
3228         cf_xopen_source="-D__EXTENSIONS__"
3229         ;;
3230 *)
3231         CF_TRY_XOPEN_SOURCE
3232         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3233         ;;
3234 esac
3235
3236 if test -n "$cf_xopen_source" ; then
3237         CF_ADD_CFLAGS($cf_xopen_source)
3238 fi
3239
3240 dnl In anything but the default case, we may have system-specific setting
3241 dnl which is still not guaranteed to provide all of the entrypoints that
3242 dnl _XOPEN_SOURCE would yield.
3243 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
3244         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
3245         AC_TRY_COMPILE([#include <stdlib.h>],[
3246 #ifndef _XOPEN_SOURCE
3247 make an error
3248 #endif],
3249         [cf_XOPEN_SOURCE_set=yes],
3250         [cf_XOPEN_SOURCE_set=no])
3251         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
3252         if test $cf_XOPEN_SOURCE_set = yes
3253         then
3254                 AC_TRY_COMPILE([#include <stdlib.h>],[
3255 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
3256 make an error
3257 #endif],
3258                 [cf_XOPEN_SOURCE_set_ok=yes],
3259                 [cf_XOPEN_SOURCE_set_ok=no])
3260                 if test $cf_XOPEN_SOURCE_set_ok = no
3261                 then
3262                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
3263                 fi
3264         else
3265                 CF_TRY_XOPEN_SOURCE
3266         fi
3267 fi
3268 ])
3269 dnl ---------------------------------------------------------------------------
3270 dnl CF_X_ATHENA version: 20 updated: 2010/11/09 05:18:02
3271 dnl -----------
3272 dnl Check for Xaw (Athena) libraries
3273 dnl
3274 dnl Sets $cf_x_athena according to the flavor of Xaw which is used.
3275 AC_DEFUN([CF_X_ATHENA],
3276 [
3277 cf_x_athena=${cf_x_athena:-Xaw}
3278
3279 AC_MSG_CHECKING(if you want to link with Xaw 3d library)
3280 withval=
3281 AC_ARG_WITH(Xaw3d,
3282         [  --with-Xaw3d            link with Xaw 3d library])
3283 if test "$withval" = yes ; then
3284         cf_x_athena=Xaw3d
3285         AC_MSG_RESULT(yes)
3286 else
3287         AC_MSG_RESULT(no)
3288 fi
3289
3290 AC_MSG_CHECKING(if you want to link with neXT Athena library)
3291 withval=
3292 AC_ARG_WITH(neXtaw,
3293         [  --with-neXtaw           link with neXT Athena library])
3294 if test "$withval" = yes ; then
3295         cf_x_athena=neXtaw
3296         AC_MSG_RESULT(yes)
3297 else
3298         AC_MSG_RESULT(no)
3299 fi
3300
3301 AC_MSG_CHECKING(if you want to link with Athena-Plus library)
3302 withval=
3303 AC_ARG_WITH(XawPlus,
3304         [  --with-XawPlus          link with Athena-Plus library])
3305 if test "$withval" = yes ; then
3306         cf_x_athena=XawPlus
3307         AC_MSG_RESULT(yes)
3308 else
3309         AC_MSG_RESULT(no)
3310 fi
3311
3312 cf_x_athena_lib=""
3313
3314 if test "$PKG_CONFIG" != none ; then
3315         cf_athena_list=
3316         test "$cf_x_athena" = Xaw && cf_athena_list="xaw8 xaw7 xaw6"
3317         for cf_athena_pkg in \
3318                 $cf_athena_list \
3319                 ${cf_x_athena} \
3320                 ${cf_x_athena}-devel \
3321                 lib${cf_x_athena} \
3322                 lib${cf_x_athena}-devel
3323         do
3324                 CF_TRY_PKG_CONFIG($cf_athena_pkg,[
3325                         cf_x_athena_lib="$cf_pkgconfig_libs"
3326                         CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
3327                         AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
3328
3329 AC_CACHE_CHECK(for usable $cf_x_athena/Xmu package,cf_cv_xaw_compat,[
3330 AC_TRY_LINK([
3331 #include <X11/Xmu/CharSet.h>
3332 ],[
3333 int check = XmuCompareISOLatin1("big", "small")
3334 ],[cf_cv_xaw_compat=yes],[cf_cv_xaw_compat=no])])
3335
3336                         if test "$cf_cv_xaw_compat" = no
3337                         then
3338                                 # workaround for broken ".pc" files...
3339                                 case "$cf_x_athena_lib" in #(vi
3340                                 *-lXmu*) #(vi
3341                                         ;;
3342                                 *)
3343                                         CF_VERBOSE(work around broken package)
3344                                         CF_TRY_PKG_CONFIG(xmu,,[CF_ADD_LIB_AFTER(-lXt,-lXmu)])
3345                                         ;;
3346                                 esac
3347                         fi
3348
3349                         break])
3350         done
3351 fi
3352
3353 if test -z "$cf_x_athena_lib" ; then
3354         CF_X_EXT
3355         CF_X_TOOLKIT
3356         CF_X_ATHENA_CPPFLAGS($cf_x_athena)
3357         CF_X_ATHENA_LIBS($cf_x_athena)
3358 fi
3359 ])dnl
3360 dnl ---------------------------------------------------------------------------
3361 dnl CF_X_ATHENA_CPPFLAGS version: 5 updated: 2010/05/26 17:35:30
3362 dnl --------------------
3363 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
3364 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
3365 AC_DEFUN([CF_X_ATHENA_CPPFLAGS],
3366 [
3367 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
3368 cf_x_athena_inc=""
3369
3370 for cf_path in default \
3371         /usr/contrib/X11R6 \
3372         /usr/contrib/X11R5 \
3373         /usr/lib/X11R5 \
3374         /usr/local
3375 do
3376         if test -z "$cf_x_athena_inc" ; then
3377                 cf_save="$CPPFLAGS"
3378                 cf_test=X11/$cf_x_athena_root/SimpleMenu.h
3379                 if test $cf_path != default ; then
3380                         CPPFLAGS="$cf_save -I$cf_path/include"
3381                         AC_MSG_CHECKING(for $cf_test in $cf_path)
3382                 else
3383                         AC_MSG_CHECKING(for $cf_test)
3384                 fi
3385                 AC_TRY_COMPILE([
3386 #include <X11/Intrinsic.h>
3387 #include <$cf_test>],[],
3388                         [cf_result=yes],
3389                         [cf_result=no])
3390                 AC_MSG_RESULT($cf_result)
3391                 if test "$cf_result" = yes ; then
3392                         cf_x_athena_inc=$cf_path
3393                         break
3394                 else
3395                         CPPFLAGS="$cf_save"
3396                 fi
3397         fi
3398 done
3399
3400 if test -z "$cf_x_athena_inc" ; then
3401         AC_MSG_WARN(
3402 [Unable to successfully find Athena header files with test program])
3403 elif test "$cf_x_athena_inc" != default ; then
3404         CPPFLAGS="$CPPFLAGS -I$cf_x_athena_inc"
3405 fi
3406 ])
3407 dnl ---------------------------------------------------------------------------
3408 dnl CF_X_ATHENA_LIBS version: 12 updated: 2011/07/17 19:55:02
3409 dnl ----------------
3410 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
3411 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
3412 AC_DEFUN([CF_X_ATHENA_LIBS],
3413 [AC_REQUIRE([CF_X_TOOLKIT])
3414 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
3415 cf_x_athena_lib=""
3416
3417 for cf_path in default \
3418         /usr/contrib/X11R6 \
3419         /usr/contrib/X11R5 \
3420         /usr/lib/X11R5 \
3421         /usr/local
3422 do
3423         for cf_lib in \
3424                 ${cf_x_athena_root} \
3425                 ${cf_x_athena_root}7 \
3426                 ${cf_x_athena_root}6
3427         do
3428         for cf_libs in \
3429                 "-l$cf_lib -lXmu" \
3430                 "-l$cf_lib -lXpm -lXmu" \
3431                 "-l${cf_lib}_s -lXmu_s"
3432         do
3433                 if test -z "$cf_x_athena_lib" ; then
3434                         cf_save="$LIBS"
3435                         cf_test=XawSimpleMenuAddGlobalActions
3436                         if test $cf_path != default ; then
3437                                 CF_ADD_LIBS(-L$cf_path/lib $cf_libs)
3438                                 AC_MSG_CHECKING(for $cf_libs in $cf_path)
3439                         else
3440                                 CF_ADD_LIBS($cf_libs)
3441                                 AC_MSG_CHECKING(for $cf_test in $cf_libs)
3442                         fi
3443                         AC_TRY_LINK([
3444 #include <X11/Intrinsic.h>
3445 #include <X11/$cf_x_athena_root/SimpleMenu.h>
3446 ],[
3447 $cf_test((XtAppContext) 0)],
3448                                 [cf_result=yes],
3449                                 [cf_result=no])
3450                         AC_MSG_RESULT($cf_result)
3451                         if test "$cf_result" = yes ; then
3452                                 cf_x_athena_lib="$cf_libs"
3453                                 break
3454                         fi
3455                         LIBS="$cf_save"
3456                 fi
3457         done # cf_libs
3458                 test -n "$cf_x_athena_lib" && break
3459         done # cf_lib
3460 done
3461
3462 if test -z "$cf_x_athena_lib" ; then
3463         AC_MSG_ERROR(
3464 [Unable to successfully link Athena library (-l$cf_x_athena_root) with test program])
3465 fi
3466
3467 CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
3468 AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
3469 ])
3470 dnl ---------------------------------------------------------------------------
3471 dnl CF_X_EXT version: 3 updated: 2010/06/02 05:03:05
3472 dnl --------
3473 AC_DEFUN([CF_X_EXT],[
3474 CF_TRY_PKG_CONFIG(Xext,,[
3475         AC_CHECK_LIB(Xext,XextCreateExtension,
3476                 [CF_ADD_LIB(Xext)])])
3477 ])dnl
3478 dnl ---------------------------------------------------------------------------
3479 dnl CF_X_TOOLKIT version: 20 updated: 2010/11/19 05:43:04
3480 dnl ------------
3481 dnl Check for X Toolkit libraries
3482 dnl
3483 AC_DEFUN([CF_X_TOOLKIT],
3484 [
3485 AC_REQUIRE([AC_PATH_XTRA])
3486 AC_REQUIRE([CF_CHECK_CACHE])
3487
3488 cf_have_X_LIBS=no
3489
3490 CF_TRY_PKG_CONFIG(xt,[
3491
3492         case "x$LIBS" in #(vi
3493         *-lX11*) #(vi
3494                 ;;
3495         *)
3496 # we have an "xt" package, but it may omit Xt's dependency on X11
3497 AC_CACHE_CHECK(for usable X dependency,cf_cv_xt_x11_compat,[
3498 AC_TRY_LINK([
3499 #include <X11/Xlib.h>
3500 ],[
3501         int rc1 = XDrawLine((Display*) 0, (Drawable) 0, (GC) 0, 0, 0, 0, 0);
3502         int rc2 = XClearWindow((Display*) 0, (Window) 0);
3503         int rc3 = XMoveWindow((Display*) 0, (Window) 0, 0, 0);
3504         int rc4 = XMoveResizeWindow((Display*)0, (Window)0, 0, 0, 0, 0);
3505 ],[cf_cv_xt_x11_compat=yes],[cf_cv_xt_x11_compat=no])])
3506                 if test "$cf_cv_xt_x11_compat" = no
3507                 then
3508                         CF_VERBOSE(work around broken X11 dependency)
3509                         # 2010/11/19 - good enough until a working Xt on Xcb is delivered.
3510                         CF_TRY_PKG_CONFIG(x11,,[CF_ADD_LIB_AFTER(-lXt,-lX11)])
3511                 fi
3512                 ;;
3513         esac
3514
3515 AC_CACHE_CHECK(for usable X Toolkit package,cf_cv_xt_ice_compat,[
3516 AC_TRY_LINK([
3517 #include <X11/Shell.h>
3518 ],[int num = IceConnectionNumber(0)
3519 ],[cf_cv_xt_ice_compat=yes],[cf_cv_xt_ice_compat=no])])
3520
3521         if test "$cf_cv_xt_ice_compat" = no
3522         then
3523                 # workaround for broken ".pc" files used for X Toolkit.
3524                 case "x$X_PRE_LIBS" in #(vi
3525                 *-lICE*)
3526                         case "x$LIBS" in #(vi
3527                         *-lICE*) #(vi
3528                                 ;;
3529                         *)
3530                                 CF_VERBOSE(work around broken ICE dependency)
3531                                 CF_TRY_PKG_CONFIG(ice,
3532                                         [CF_TRY_PKG_CONFIG(sm)],
3533                                         [CF_ADD_LIB_AFTER(-lXt,$X_PRE_LIBS)])
3534                                 ;;
3535                         esac
3536                         ;;
3537                 esac
3538         fi
3539
3540         cf_have_X_LIBS=yes
3541 ],[
3542
3543         LDFLAGS="$X_LIBS $LDFLAGS"
3544         CF_CHECK_CFLAGS($X_CFLAGS)
3545
3546         AC_CHECK_FUNC(XOpenDisplay,,[
3547         AC_CHECK_LIB(X11,XOpenDisplay,
3548                 [CF_ADD_LIB(X11)],,
3549                 [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])])
3550
3551         AC_CHECK_FUNC(XtAppInitialize,,[
3552         AC_CHECK_LIB(Xt, XtAppInitialize,
3553                 [AC_DEFINE(HAVE_LIBXT)
3554                  cf_have_X_LIBS=Xt
3555                  LIBS="-lXt $X_PRE_LIBS $LIBS $X_EXTRA_LIBS"],,
3556                 [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])])
3557 ])
3558
3559 if test $cf_have_X_LIBS = no ; then
3560         AC_MSG_WARN(
3561 [Unable to successfully link X Toolkit library (-lXt) with
3562 test program.  You will have to check and add the proper libraries by hand
3563 to makefile.])
3564 fi
3565 ])dnl
3566 dnl ---------------------------------------------------------------------------
3567 dnl CF__CURSES_HEAD version: 2 updated: 2010/10/23 15:54:49
3568 dnl ---------------
3569 dnl Define a reusable chunk which includes <curses.h> and <term.h> when they
3570 dnl are both available.
3571 define([CF__CURSES_HEAD],[
3572 #ifdef HAVE_XCURSES
3573 #include <xcurses.h>
3574 char * XCursesProgramName = "test";
3575 #else
3576 #include <${cf_cv_ncurses_header:-curses.h}>
3577 #if defined(NCURSES_VERSION) && defined(HAVE_NCURSESW_TERM_H)
3578 #include <ncursesw/term.h>
3579 #elif defined(NCURSES_VERSION) && defined(HAVE_NCURSES_TERM_H)
3580 #include <ncurses/term.h>
3581 #elif defined(HAVE_TERM_H)
3582 #include <term.h>
3583 #endif
3584 #endif
3585 ])