ncurses 6.0 - patch 20170909
[ncurses.git] / test / aclocal.m4
1 dnl***************************************************************************
2 dnl Copyright (c) 2003-2016,2017 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl $Id: aclocal.m4,v 1.144 2017/09/07 21:08:12 tom Exp $
30 dnl
31 dnl Author: Thomas E. Dickey
32 dnl
33 dnl Macros used in NCURSES test programs auto-configuration script.
34 dnl
35 dnl These macros are maintained separately from NCURSES.  The copyright on
36 dnl this file applies to the aggregation of macros and does not affect use of
37 dnl these macros in other applications.
38 dnl
39 dnl See http://invisible-island.net/autoconf/ for additional information.
40 dnl
41 dnl ---------------------------------------------------------------------------
42 dnl ---------------------------------------------------------------------------
43 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
44 dnl -------------------
45 dnl Inserted as requested by gettext 0.10.40
46 dnl File from /usr/share/aclocal
47 dnl codeset.m4
48 dnl ====================
49 dnl serial AM1
50 dnl
51 dnl From Bruno Haible.
52 AC_DEFUN([AM_LANGINFO_CODESET],
53 [
54 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
55         [AC_TRY_LINK([#include <langinfo.h>],
56         [char* cs = nl_langinfo(CODESET);],
57         am_cv_langinfo_codeset=yes,
58         am_cv_langinfo_codeset=no)
59         ])
60         if test $am_cv_langinfo_codeset = yes; then
61                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
62                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
63         fi
64 ])dnl
65 dnl ---------------------------------------------------------------------------
66 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
67 dnl ------------------
68 dnl Conditionally generate script according to whether we're using a given autoconf.
69 dnl
70 dnl $1 = version to compare against
71 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
72 dnl $3 = code to use if AC_ACVERSION is older than $1.
73 define([CF_ACVERSION_CHECK],
74 [
75 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
76 ifdef([m4_version_compare],
77 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
78 [CF_ACVERSION_COMPARE(
79 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
80 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
81 dnl ---------------------------------------------------------------------------
82 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
83 dnl --------------------
84 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
85 dnl                      MAJOR2, MINOR2, TERNARY2,
86 dnl                      PRINTABLE2, not FOUND, FOUND)
87 define([CF_ACVERSION_COMPARE],
88 [ifelse(builtin([eval], [$2 < $5]), 1,
89 [ifelse([$8], , ,[$8])],
90 [ifelse([$9], , ,[$9])])])dnl
91 dnl ---------------------------------------------------------------------------
92 dnl CF_ADD_CFLAGS version: 13 updated: 2017/02/25 18:57:40
93 dnl -------------
94 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
95 dnl The second parameter if given makes this macro verbose.
96 dnl
97 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
98 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
99 dnl confused by the quotes (which require backslashes to keep them usable).
100 AC_DEFUN([CF_ADD_CFLAGS],
101 [
102 cf_fix_cppflags=no
103 cf_new_cflags=
104 cf_new_cppflags=
105 cf_new_extra_cppflags=
106
107 for cf_add_cflags in $1
108 do
109 case $cf_fix_cppflags in
110 (no)
111         case $cf_add_cflags in
112         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
113                 case $cf_add_cflags in
114                 (-D*)
115                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
116
117                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
118                                 && test -z "${cf_tst_cflags}" \
119                                 && cf_fix_cppflags=yes
120
121                         if test $cf_fix_cppflags = yes ; then
122                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
123                                 continue
124                         elif test "${cf_tst_cflags}" = "\"'" ; then
125                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
126                                 continue
127                         fi
128                         ;;
129                 esac
130                 case "$CPPFLAGS" in
131                 (*$cf_add_cflags)
132                         ;;
133                 (*)
134                         case $cf_add_cflags in
135                         (-D*)
136                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
137                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
138                                 ;;
139                         esac
140                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
141                         ;;
142                 esac
143                 ;;
144         (*)
145                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
146                 ;;
147         esac
148         ;;
149 (yes)
150         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
151
152         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
153
154         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
155                 && test -z "${cf_tst_cflags}" \
156                 && cf_fix_cppflags=no
157         ;;
158 esac
159 done
160
161 if test -n "$cf_new_cflags" ; then
162         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
163         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
164 fi
165
166 if test -n "$cf_new_cppflags" ; then
167         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
168         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
169 fi
170
171 if test -n "$cf_new_extra_cppflags" ; then
172         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
173         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
174 fi
175
176 AC_SUBST(EXTRA_CPPFLAGS)
177
178 ])dnl
179 dnl ---------------------------------------------------------------------------
180 dnl CF_ADD_INCDIR version: 14 updated: 2015/05/25 20:53:04
181 dnl -------------
182 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
183 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
184 dnl but old versions (and some misinstalled ones) need that.  To make things
185 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
186 dnl the include-path).
187 AC_DEFUN([CF_ADD_INCDIR],
188 [
189 if test -n "$1" ; then
190   for cf_add_incdir in $1
191   do
192         while test $cf_add_incdir != /usr/include
193         do
194           if test -d $cf_add_incdir
195           then
196                 cf_have_incdir=no
197                 if test -n "$CFLAGS$CPPFLAGS" ; then
198                   # a loop is needed to ensure we can add subdirs of existing dirs
199                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
200                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
201                           cf_have_incdir=yes; break
202                         fi
203                   done
204                 fi
205
206                 if test "$cf_have_incdir" = no ; then
207                   if test "$cf_add_incdir" = /usr/local/include ; then
208                         if test "$GCC" = yes
209                         then
210                           cf_save_CPPFLAGS=$CPPFLAGS
211                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
212                           AC_TRY_COMPILE([#include <stdio.h>],
213                                   [printf("Hello")],
214                                   [],
215                                   [cf_have_incdir=yes])
216                           CPPFLAGS=$cf_save_CPPFLAGS
217                         fi
218                   fi
219                 fi
220
221                 if test "$cf_have_incdir" = no ; then
222                   CF_VERBOSE(adding $cf_add_incdir to include-path)
223                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
224
225                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
226                   test "$cf_top_incdir" = "$cf_add_incdir" && break
227                   cf_add_incdir="$cf_top_incdir"
228                 else
229                   break
230                 fi
231           else
232                 break
233           fi
234         done
235   done
236 fi
237 ])dnl
238 dnl ---------------------------------------------------------------------------
239 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
240 dnl ----------
241 dnl Add a library, used to enforce consistency.
242 dnl
243 dnl $1 = library to add, without the "-l"
244 dnl $2 = variable to update (default $LIBS)
245 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
246 dnl ---------------------------------------------------------------------------
247 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
248 dnl -------------
249 dnl     Adds to the library-path
250 dnl
251 dnl     Some machines have trouble with multiple -L options.
252 dnl
253 dnl $1 is the (list of) directory(s) to add
254 dnl $2 is the optional name of the variable to update (default LDFLAGS)
255 dnl
256 AC_DEFUN([CF_ADD_LIBDIR],
257 [
258 if test -n "$1" ; then
259         for cf_add_libdir in $1
260         do
261                 if test $cf_add_libdir = /usr/lib ; then
262                         :
263                 elif test -d $cf_add_libdir
264                 then
265                         cf_have_libdir=no
266                         if test -n "$LDFLAGS$LIBS" ; then
267                                 # a loop is needed to ensure we can add subdirs of existing dirs
268                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
269                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
270                                                 cf_have_libdir=yes; break
271                                         fi
272                                 done
273                         fi
274                         if test "$cf_have_libdir" = no ; then
275                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
276                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
277                         fi
278                 fi
279         done
280 fi
281 ])dnl
282 dnl ---------------------------------------------------------------------------
283 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
284 dnl -----------
285 dnl Add one or more libraries, used to enforce consistency.  Libraries are
286 dnl prepended to an existing list, since their dependencies are assumed to
287 dnl already exist in the list.
288 dnl
289 dnl $1 = libraries to add, with the "-l", etc.
290 dnl $2 = variable to update (default $LIBS)
291 AC_DEFUN([CF_ADD_LIBS],[
292 cf_add_libs="$1"
293 # Filter out duplicates - this happens with badly-designed ".pc" files...
294 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
295 do
296         for cf_add_2lib in $cf_add_libs
297         do
298                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
299                 then
300                         cf_add_1lib=
301                         break
302                 fi
303         done
304         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
305 done
306 ifelse($2,,LIBS,[$2])="$cf_add_libs"
307 ])dnl
308 dnl ---------------------------------------------------------------------------
309 dnl CF_ADD_LIB_AFTER version: 3 updated: 2013/07/09 21:27:22
310 dnl ----------------
311 dnl Add a given library after another, e.g., following the one it satisfies a
312 dnl dependency for.
313 dnl
314 dnl $1 = the first library
315 dnl $2 = its dependency
316 AC_DEFUN([CF_ADD_LIB_AFTER],[
317 CF_VERBOSE(...before $LIBS)
318 LIBS=`echo "$LIBS" | sed -e "s/[[       ]][[    ]]*/ /g" -e "s%$1 %$1 $2 %" -e 's%  % %g'`
319 CF_VERBOSE(...after  $LIBS)
320 ])dnl
321 dnl ---------------------------------------------------------------------------
322 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
323 dnl ------------------
324 dnl Append to a search-list for a nonstandard header/lib-file
325 dnl     $1 = the variable to return as result
326 dnl     $2 = the package name
327 dnl     $3 = the subdirectory, e.g., bin, include or lib
328 dnl $4 = the directory under which we will test for subdirectories
329 dnl $5 = a directory that we do not want $4 to match
330 AC_DEFUN([CF_ADD_SUBDIR_PATH],
331 [
332 test "x$4" != "x$5" && \
333 test -d "$4" && \
334 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
335         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
336         test -d $4/$3 &&          $1="[$]$1 $4/$3"
337         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
338         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
339         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
340         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
341 }
342 ])dnl
343 dnl ---------------------------------------------------------------------------
344 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
345 dnl --------------
346 dnl use this macro for appending text without introducing an extra blank at
347 dnl the beginning
348 define([CF_APPEND_TEXT],
349 [
350         test -n "[$]$1" && $1="[$]$1 "
351         $1="[$]{$1}$2"
352 ])dnl
353 dnl ---------------------------------------------------------------------------
354 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
355 dnl --------------
356 dnl Allow user to disable a normally-on option.
357 AC_DEFUN([CF_ARG_DISABLE],
358 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
359 dnl ---------------------------------------------------------------------------
360 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
361 dnl -------------
362 dnl Allow user to enable a normally-off option.
363 AC_DEFUN([CF_ARG_ENABLE],
364 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
365 dnl ---------------------------------------------------------------------------
366 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
367 dnl -------------
368 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
369 dnl values.
370 dnl
371 dnl Parameters:
372 dnl $1 = option name
373 dnl $2 = help-string
374 dnl $3 = action to perform if option is not default
375 dnl $4 = action if perform if option is default
376 dnl $5 = default option value (either 'yes' or 'no')
377 AC_DEFUN([CF_ARG_OPTION],
378 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
379         if test "$enableval" != "$5" ; then
380 ifelse([$3],,[    :]dnl
381 ,[    $3]) ifelse([$4],,,[
382         else
383                 $4])
384         fi],[enableval=$5 ifelse([$4],,,[
385         $4
386 ])dnl
387 ])])dnl
388 dnl ---------------------------------------------------------------------------
389 dnl CF_CC_ENV_FLAGS version: 7 updated: 2017/02/25 18:57:40
390 dnl ---------------
391 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
392 dnl into CC.  This will not help with broken scripts that wrap the compiler
393 dnl with options, but eliminates a more common category of user confusion.
394 dnl
395 dnl In particular, it addresses the problem of being able to run the C
396 dnl preprocessor in a consistent manner.
397 dnl
398 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
399 dnl the nuisance of having inconsistent settings for compiler and preprocessor
400 dnl outweighs that limitation.
401 AC_DEFUN([CF_CC_ENV_FLAGS],
402 [
403 # This should have been defined by AC_PROG_CC
404 : ${CC:=cc}
405
406 AC_MSG_CHECKING(\$CC variable)
407 case "$CC" in
408 (*[[\ \ ]]-*)
409         AC_MSG_RESULT(broken)
410         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
411         # humor him...
412         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
413         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", substr([$]0,1+length(prog))); }'`
414         CC="$cf_prog"
415         for cf_arg in $cf_flags
416         do
417                 case "x$cf_arg" in
418                 (x-[[IUDfgOW]]*)
419                         CF_ADD_CFLAGS($cf_arg)
420                         ;;
421                 (*)
422                         CC="$CC $cf_arg"
423                         ;;
424                 esac
425         done
426         CF_VERBOSE(resulting CC: '$CC')
427         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
428         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
429         ;;
430 (*)
431         AC_MSG_RESULT(ok)
432         ;;
433 esac
434 ])dnl
435 dnl ---------------------------------------------------------------------------
436 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
437 dnl --------------
438 dnl Check if we're accidentally using a cache from a different machine.
439 dnl Derive the system name, as a check for reusing the autoconf cache.
440 dnl
441 dnl If we've packaged config.guess and config.sub, run that (since it does a
442 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
443 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
444 dnl which is useful in cross-compiles.
445 dnl
446 dnl Note: we would use $ac_config_sub, but that is one of the places where
447 dnl autoconf 2.5x broke compatibility with autoconf 2.13
448 AC_DEFUN([CF_CHECK_CACHE],
449 [
450 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
451         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
452         system_name="$host_os"
453 else
454         system_name="`(uname -s -r) 2>/dev/null`"
455         if test -z "$system_name" ; then
456                 system_name="`(hostname) 2>/dev/null`"
457         fi
458 fi
459 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
460 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
461
462 test -z "$system_name" && system_name="$cf_cv_system_name"
463 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
464
465 if test ".$system_name" != ".$cf_cv_system_name" ; then
466         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
467         AC_MSG_ERROR("Please remove config.cache and try again.")
468 fi
469 ])dnl
470 dnl ---------------------------------------------------------------------------
471 dnl CF_CHECK_CFLAGS version: 3 updated: 2014/07/22 05:32:57
472 dnl ---------------
473 dnl Conditionally add to $CFLAGS and $CPPFLAGS values which are derived from
474 dnl a build-configuration such as imake.  These have the pitfall that they
475 dnl often contain compiler-specific options which we cannot use, mixed with
476 dnl preprocessor options that we usually can.
477 AC_DEFUN([CF_CHECK_CFLAGS],
478 [
479 CF_VERBOSE(checking additions to CFLAGS)
480 cf_check_cflags="$CFLAGS"
481 cf_check_cppflags="$CPPFLAGS"
482 CF_ADD_CFLAGS($1,yes)
483 if test "x$cf_check_cflags" != "x$CFLAGS" ; then
484 AC_TRY_LINK([#include <stdio.h>],[printf("Hello world");],,
485         [CF_VERBOSE(test-compile failed.  Undoing change to \$CFLAGS)
486          if test "x$cf_check_cppflags" != "x$CPPFLAGS" ; then
487                  CF_VERBOSE(but keeping change to \$CPPFLAGS)
488          fi
489          CFLAGS="$cf_check_flags"])
490 fi
491 ])dnl
492 dnl ---------------------------------------------------------------------------
493 dnl CF_CHECK_CURSES_LIB version: 1 updated: 2015/04/25 20:53:11
494 dnl -------------------
495 dnl $1 = nominal library name, used also for header lookup
496 dnl $2 = suffix to append to library name
497 dnl $3 = function to check for using AC_CHECK_LIB
498 AC_DEFUN([CF_CHECK_CURSES_LIB],
499 [
500 AC_CHECK_LIB($1$2,$3,[
501 CF_UPPER(cf_upper,have_lib$1)
502 CF_ADD_LIBS(-l$1$2)
503 AC_DEFINE_UNQUOTED($cf_upper,1)])
504 ])dnl
505 dnl ---------------------------------------------------------------------------
506 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
507 dnl -----------------
508 dnl Check if the given compiler is really clang.  clang's C driver defines
509 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
510 dnl not ignore some gcc options.
511 dnl
512 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
513 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
514 dnl the wrappers for gcc and g++ warnings.
515 dnl
516 dnl $1 = GCC (default) or GXX
517 dnl $2 = CLANG_COMPILER (default)
518 dnl $3 = CFLAGS (default) or CXXFLAGS
519 AC_DEFUN([CF_CLANG_COMPILER],[
520 ifelse([$2],,CLANG_COMPILER,[$2])=no
521
522 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
523         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
524         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
525         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
526         AC_TRY_COMPILE([],[
527 #ifdef __clang__
528 #else
529 make an error
530 #endif
531 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
532 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
533 ],[])
534         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
535         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
536 fi
537 ])
538 dnl ---------------------------------------------------------------------------
539 dnl CF_CURSES_ACS_MAP version: 7 updated: 2012/10/06 16:39:58
540 dnl -----------------
541 dnl Check for likely values of acs_map[]:
542 AC_DEFUN([CF_CURSES_ACS_MAP],
543 [
544 AC_REQUIRE([CF_NCURSES_WRAP_PREFIX])dnl
545 AC_CACHE_CHECK(for alternate character set array, cf_cv_curses_acs_map,[
546 cf_cv_curses_acs_map=unknown
547 for name in acs_map _acs_map __acs_map ${NCURSES_WRAP_PREFIX}acs_map
548 do
549 AC_TRY_LINK([
550 #include <${cf_cv_ncurses_header:-curses.h}>
551 ],[
552 $name['k'] = ACS_PLUS
553 ],[cf_cv_curses_acs_map=$name; break])
554 done
555 ])
556
557 test "$cf_cv_curses_acs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_ACS_ARRAY,$cf_cv_curses_acs_map,[Define as needed to override ncurses prefix _nc_])
558 ])
559 dnl ---------------------------------------------------------------------------
560 dnl CF_CURSES_CHECK_DATA version: 6 updated: 2017/07/28 19:05:31
561 dnl --------------------
562 dnl Check if curses.h defines the given data/variable.
563 dnl Use this after CF_NCURSES_CONFIG or CF_CURSES_CONFIG.
564 dnl
565 dnl $1 = data item(s) to check for
566 dnl $2 = action on success, e.g., "break" to quit checking a series of choices
567 AC_DEFUN([CF_CURSES_CHECK_DATA],
568 [
569 for cf_data in $1
570 do
571 AC_MSG_CHECKING(for data $cf_data declaration in ${cf_cv_ncurses_header:-curses.h})
572
573 AC_TRY_COMPILE(CF__CURSES_HEAD,[
574 void *foo = &($cf_data)
575 ],[cf_result=yes
576 ],[cf_result=no])
577 AC_MSG_RESULT($cf_result)
578
579 if test $cf_result = yes ; then
580         CF_UPPER(cf_result,have_curses_data_$cf_data)
581         AC_DEFINE_UNQUOTED($cf_result)
582         ifelse($2,,,[$2])
583 else
584         AC_MSG_CHECKING(for data $cf_data in library)
585         # BSD linkers insist on making weak linkage, but resolve at runtime.
586         AC_TRY_RUN(CF__CURSES_HEAD
587 [
588 extern char $cf_data;
589 int main(void)
590 {
591         void *foo = &($cf_data);
592         fprintf(stderr, "testing linkage of $cf_data:%p\n", foo);
593         ${cf_cv_main_return:-return}(foo == 0);
594 }],[cf_result=yes
595 ],[cf_result=no],[
596         # cross-compiling
597         AC_TRY_LINK(CF__CURSES_HEAD
598 [extern char $cf_data;],[
599         do {
600                 void *foo = &($cf_data);
601                 fprintf(stderr, "testing linkage of $cf_data:%p\n", foo);
602                 ${cf_cv_main_return:-return}(foo == 0);
603         } while (0)
604 ],[cf_result=yes],[cf_result=no])
605 ])
606         AC_MSG_RESULT($cf_result)
607         if test $cf_result = yes ; then
608                 CF_UPPER(cf_result,decl_curses_data_$cf_data)
609                 AC_DEFINE_UNQUOTED($cf_result)
610                 # do not exit loop here, since we prefer system's declarations
611         fi
612 fi
613 done
614 ])dnl
615 dnl ---------------------------------------------------------------------------
616 dnl CF_CURSES_CHECK_TYPE version: 4 updated: 2012/10/06 16:39:58
617 dnl --------------------
618 dnl Check if curses.h defines the given type
619 AC_DEFUN([CF_CURSES_CHECK_TYPE],
620 [
621 AC_MSG_CHECKING(for type $1 in ${cf_cv_ncurses_header:-curses.h})
622 AC_TRY_COMPILE([
623 #ifndef _XOPEN_SOURCE_EXTENDED
624 #define _XOPEN_SOURCE_EXTENDED
625 #endif
626 #include <${cf_cv_ncurses_header:-curses.h}>],[
627 $1 foo
628 ],cf_result=yes,cf_result=no)
629 AC_MSG_RESULT($cf_result)
630 if test $cf_result = yes ; then
631         CF_UPPER(cf_result,have_type_$1)
632         AC_DEFINE_UNQUOTED($cf_result,1,[Define to 1 if we have type $1])
633 else
634         AC_DEFINE_UNQUOTED($1,$2,[Define to appropriate type if $1 is not declared])
635 fi
636 ])dnl
637 dnl ---------------------------------------------------------------------------
638 dnl CF_CURSES_CONFIG version: 2 updated: 2006/10/29 11:06:27
639 dnl ----------------
640 dnl Tie together the configure-script macros for curses.  It may be ncurses,
641 dnl but unless asked, we do not make a special search for ncurses.  However,
642 dnl still check for the ncurses version number, for use in other macros.
643 AC_DEFUN([CF_CURSES_CONFIG],
644 [
645 CF_CURSES_CPPFLAGS
646 CF_NCURSES_VERSION
647 CF_CURSES_LIBS
648 ])dnl
649 dnl ---------------------------------------------------------------------------
650 dnl CF_CURSES_CPPFLAGS version: 12 updated: 2015/04/15 19:08:48
651 dnl ------------------
652 dnl Look for the curses headers.
653 AC_DEFUN([CF_CURSES_CPPFLAGS],[
654
655 AC_CACHE_CHECK(for extra include directories,cf_cv_curses_incdir,[
656 cf_cv_curses_incdir=no
657 case $host_os in
658 (hpux10.*)
659         if test "x$cf_cv_screen" = "xcurses_colr"
660         then
661                 test -d /usr/include/curses_colr && \
662                 cf_cv_curses_incdir="-I/usr/include/curses_colr"
663         fi
664         ;;
665 (sunos3*|sunos4*)
666         if test "x$cf_cv_screen" = "xcurses_5lib"
667         then
668                 test -d /usr/5lib && \
669                 test -d /usr/5include && \
670                 cf_cv_curses_incdir="-I/usr/5include"
671         fi
672         ;;
673 esac
674 ])
675 test "$cf_cv_curses_incdir" != no && CPPFLAGS="$CPPFLAGS $cf_cv_curses_incdir"
676
677 CF_CURSES_HEADER
678 CF_TERM_HEADER
679 ])dnl
680 dnl ---------------------------------------------------------------------------
681 dnl CF_CURSES_FUNCS version: 18 updated: 2014/07/19 18:44:41
682 dnl ---------------
683 dnl Curses-functions are a little complicated, since a lot of them are macros.
684 AC_DEFUN([CF_CURSES_FUNCS],
685 [
686 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
687 AC_REQUIRE([CF_XOPEN_CURSES])
688 AC_REQUIRE([CF_CURSES_TERM_H])
689 AC_REQUIRE([CF_CURSES_UNCTRL_H])
690 for cf_func in $1
691 do
692         CF_UPPER(cf_tr_func,$cf_func)
693         AC_MSG_CHECKING(for ${cf_func})
694         CF_MSG_LOG(${cf_func})
695         AC_CACHE_VAL(cf_cv_func_$cf_func,[
696                 eval cf_result='$ac_cv_func_'$cf_func
697                 if test ".$cf_result" != ".no"; then
698                         AC_TRY_LINK(CF__CURSES_HEAD,
699                         [
700 #ifndef ${cf_func}
701 long foo = (long)(&${cf_func});
702 fprintf(stderr, "testing linkage of $cf_func:%p\n", foo);
703 if (foo + 1234 > 5678)
704         ${cf_cv_main_return:-return}(foo);
705 #endif
706                         ],
707                         [cf_result=yes],
708                         [cf_result=no])
709                 fi
710                 eval 'cf_cv_func_'$cf_func'=$cf_result'
711         ])
712         # use the computed/retrieved cache-value:
713         eval 'cf_result=$cf_cv_func_'$cf_func
714         AC_MSG_RESULT($cf_result)
715         if test $cf_result != no; then
716                 AC_DEFINE_UNQUOTED(HAVE_${cf_tr_func})
717         fi
718 done
719 ])dnl
720 dnl ---------------------------------------------------------------------------
721 dnl CF_CURSES_HEADER version: 5 updated: 2015/04/23 20:35:30
722 dnl ----------------
723 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
724 dnl variations of ncurses' installs.
725 dnl
726 dnl $1 = ncurses when looking for ncurses, or is empty
727 AC_DEFUN([CF_CURSES_HEADER],[
728 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
729 cf_cv_ncurses_header=none
730 for cf_header in \
731         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
732         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
733 do
734 AC_TRY_COMPILE([#include <${cf_header}>],
735         [initscr(); tgoto("?", 0,0)],
736         [cf_cv_ncurses_header=$cf_header; break],[])
737 done
738 ])
739
740 if test "$cf_cv_ncurses_header" = none ; then
741         AC_MSG_ERROR(No curses header-files found)
742 fi
743
744 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
745 AC_CHECK_HEADERS($cf_cv_ncurses_header)
746 ])dnl
747 dnl ---------------------------------------------------------------------------
748 dnl CF_CURSES_LIBS version: 40 updated: 2017/09/07 17:06:24
749 dnl --------------
750 dnl Look for the curses libraries.  Older curses implementations may require
751 dnl termcap/termlib to be linked as well.  Call CF_CURSES_CPPFLAGS first.
752 AC_DEFUN([CF_CURSES_LIBS],[
753
754 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
755 AC_MSG_CHECKING(if we have identified curses libraries)
756 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
757         [initscr(); tgoto("?", 0,0)],
758         cf_result=yes,
759         cf_result=no)
760 AC_MSG_RESULT($cf_result)
761
762 if test "$cf_result" = no ; then
763 case $host_os in
764 (freebsd*)
765         AC_CHECK_LIB(mytinfo,tgoto,[CF_ADD_LIBS(-lmytinfo)])
766         ;;
767 (hpux10.*)
768         # Looking at HPUX 10.20, the Hcurses library is the oldest (1997), cur_colr
769         # next (1998), and xcurses "newer" (2000).  There is no header file for
770         # Hcurses; the subdirectory curses_colr has the headers (curses.h and
771         # term.h) for cur_colr
772         if test "x$cf_cv_screen" = "xcurses_colr"
773         then
774                 AC_CHECK_LIB(cur_colr,initscr,[
775                         CF_ADD_LIBS(-lcur_colr)
776                         ac_cv_func_initscr=yes
777                         ],[
778                 AC_CHECK_LIB(Hcurses,initscr,[
779                         # HP's header uses __HP_CURSES, but user claims _HP_CURSES.
780                         CF_ADD_LIBS(-lHcurses)
781                         CPPFLAGS="$CPPFLAGS -D__HP_CURSES -D_HP_CURSES"
782                         ac_cv_func_initscr=yes
783                         ])])
784         fi
785         ;;
786 (linux*)
787         case `arch 2>/dev/null` in
788         (x86_64)
789                 if test -d /lib64
790                 then
791                         CF_ADD_LIBDIR(/lib64)
792                 else
793                         CF_ADD_LIBDIR(/lib)
794                 fi
795                 ;;
796         (*)
797                 CF_ADD_LIBDIR(/lib)
798                 ;;
799         esac
800         ;;
801 (sunos3*|sunos4*)
802         if test "x$cf_cv_screen" = "xcurses_5lib"
803         then
804                 if test -d /usr/5lib ; then
805                         CF_ADD_LIBDIR(/usr/5lib)
806                         CF_ADD_LIBS(-lcurses -ltermcap)
807                 fi
808         fi
809         ac_cv_func_initscr=yes
810         ;;
811 esac
812
813 if test ".$ac_cv_func_initscr" != .yes ; then
814         cf_save_LIBS="$LIBS"
815
816         if test ".${cf_cv_ncurses_version:-no}" != .no
817         then
818                 cf_check_list="ncurses curses cursesX"
819         else
820                 cf_check_list="cursesX curses ncurses"
821         fi
822
823         # Check for library containing tgoto.  Do this before curses library
824         # because it may be needed to link the test-case for initscr.
825         if test "x$cf_term_lib" = x
826         then
827                 AC_CHECK_FUNC(tgoto,[cf_term_lib=predefined],[
828                         for cf_term_lib in $cf_check_list otermcap termcap tinfo termlib unknown
829                         do
830                                 AC_CHECK_LIB($cf_term_lib,tgoto,[break])
831                         done
832                 ])
833         fi
834
835         # Check for library containing initscr
836         test "$cf_term_lib" != predefined && test "$cf_term_lib" != unknown && LIBS="-l$cf_term_lib $cf_save_LIBS"
837         if test "x$cf_curs_lib" = x
838         then
839                 for cf_curs_lib in $cf_check_list xcurses jcurses pdcurses unknown
840                 do
841                         LIBS="-l$cf_curs_lib $cf_save_LIBS"
842                         if test "$cf_term_lib" = unknown || test "$cf_term_lib" = "$cf_curs_lib" ; then
843                                 AC_MSG_CHECKING(if we can link with $cf_curs_lib library)
844                                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
845                                         [initscr()],
846                                         [cf_result=yes],
847                                         [cf_result=no])
848                                 AC_MSG_RESULT($cf_result)
849                                 test $cf_result = yes && break
850                         elif test "$cf_curs_lib" = "$cf_term_lib" ; then
851                                 cf_result=no
852                         elif test "$cf_term_lib" != predefined ; then
853                                 AC_MSG_CHECKING(if we need both $cf_curs_lib and $cf_term_lib libraries)
854                                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
855                                         [initscr(); tgoto((char *)0, 0, 0);],
856                                         [cf_result=no],
857                                         [
858                                         LIBS="-l$cf_curs_lib -l$cf_term_lib $cf_save_LIBS"
859                                         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
860                                                 [initscr()],
861                                                 [cf_result=yes],
862                                                 [cf_result=error])
863                                         ])
864                                 AC_MSG_RESULT($cf_result)
865                                 test $cf_result != error && break
866                         fi
867                 done
868         fi
869         test $cf_curs_lib = unknown && AC_MSG_ERROR(no curses library found)
870 fi
871 fi
872
873 ])dnl
874 dnl ---------------------------------------------------------------------------
875 dnl CF_CURSES_TERM_H version: 11 updated: 2015/04/15 19:08:48
876 dnl ----------------
877 dnl SVr4 curses should have term.h as well (where it puts the definitions of
878 dnl the low-level interface).  This may not be true in old/broken implementations,
879 dnl as well as in misconfigured systems (e.g., gcc configured for Solaris 2.4
880 dnl running with Solaris 2.5.1).
881 AC_DEFUN([CF_CURSES_TERM_H],
882 [
883 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
884
885 AC_CACHE_CHECK(for term.h, cf_cv_term_header,[
886
887 # If we found <ncurses/curses.h>, look for <ncurses/term.h>, but always look
888 # for <term.h> if we do not find the variant.
889
890 cf_header_list="term.h ncurses/term.h ncursesw/term.h"
891
892 case ${cf_cv_ncurses_header:-curses.h} in
893 (*/*)
894         cf_header_item=`echo ${cf_cv_ncurses_header:-curses.h} | sed -e 's%\..*%%' -e 's%/.*%/%'`term.h
895         cf_header_list="$cf_header_item $cf_header_list"
896         ;;
897 esac
898
899 for cf_header in $cf_header_list
900 do
901         AC_TRY_COMPILE([
902 #include <${cf_cv_ncurses_header:-curses.h}>
903 #include <${cf_header}>],
904         [WINDOW *x],
905         [cf_cv_term_header=$cf_header
906          break],
907         [cf_cv_term_header=no])
908 done
909
910 case $cf_cv_term_header in
911 (no)
912         # If curses is ncurses, some packagers still mess it up by trying to make
913         # us use GNU termcap.  This handles the most common case.
914         for cf_header in ncurses/term.h ncursesw/term.h
915         do
916                 AC_TRY_COMPILE([
917 #include <${cf_cv_ncurses_header:-curses.h}>
918 #ifdef NCURSES_VERSION
919 #include <${cf_header}>
920 #else
921 make an error
922 #endif],
923                         [WINDOW *x],
924                         [cf_cv_term_header=$cf_header
925                          break],
926                         [cf_cv_term_header=no])
927         done
928         ;;
929 esac
930 ])
931
932 case $cf_cv_term_header in
933 (term.h)
934         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
935         ;;
936 (ncurses/term.h)
937         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
938         ;;
939 (ncursesw/term.h)
940         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
941         ;;
942 esac
943 ])dnl
944 dnl ---------------------------------------------------------------------------
945 dnl CF_CURSES_UNCTRL_H version: 4 updated: 2015/04/15 19:08:48
946 dnl ------------------
947 dnl Any X/Open curses implementation must have unctrl.h, but ncurses packages
948 dnl may put it in a subdirectory (along with ncurses' other headers, of
949 dnl course).  Packages which put the headers in inconsistent locations are
950 dnl broken).
951 AC_DEFUN([CF_CURSES_UNCTRL_H],
952 [
953 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
954
955 AC_CACHE_CHECK(for unctrl.h, cf_cv_unctrl_header,[
956
957 # If we found <ncurses/curses.h>, look for <ncurses/unctrl.h>, but always look
958 # for <unctrl.h> if we do not find the variant.
959
960 cf_header_list="unctrl.h ncurses/unctrl.h ncursesw/unctrl.h"
961
962 case ${cf_cv_ncurses_header:-curses.h} in
963 (*/*)
964         cf_header_item=`echo ${cf_cv_ncurses_header:-curses.h} | sed -e 's%\..*%%' -e 's%/.*%/%'`unctrl.h
965         cf_header_list="$cf_header_item $cf_header_list"
966         ;;
967 esac
968
969 for cf_header in $cf_header_list
970 do
971         AC_TRY_COMPILE([
972 #include <${cf_cv_ncurses_header:-curses.h}>
973 #include <${cf_header}>],
974         [WINDOW *x],
975         [cf_cv_unctrl_header=$cf_header
976          break],
977         [cf_cv_unctrl_header=no])
978 done
979 ])
980
981 case $cf_cv_unctrl_header in
982 (no)
983         AC_MSG_WARN(unctrl.h header not found)
984         ;;
985 esac
986
987 case $cf_cv_unctrl_header in
988 (unctrl.h)
989         AC_DEFINE(HAVE_UNCTRL_H,1,[Define to 1 if we have unctrl.h])
990         ;;
991 (ncurses/unctrl.h)
992         AC_DEFINE(HAVE_NCURSES_UNCTRL_H,1,[Define to 1 if we have ncurses/unctrl.h])
993         ;;
994 (ncursesw/unctrl.h)
995         AC_DEFINE(HAVE_NCURSESW_UNCTRL_H,1,[Define to 1 if we have ncursesw/unctrl.h])
996         ;;
997 esac
998 ])dnl
999 dnl ---------------------------------------------------------------------------
1000 dnl CF_CURSES_WACS_MAP version: 6 updated: 2012/10/06 08:57:51
1001 dnl ------------------
1002 dnl Check for likely values of wacs_map[].
1003 AC_DEFUN([CF_CURSES_WACS_MAP],
1004 [
1005 AC_CACHE_CHECK(for wide alternate character set array, cf_cv_curses_wacs_map,[
1006         cf_cv_curses_wacs_map=unknown
1007         for name in wacs_map _wacs_map __wacs_map _nc_wacs _wacs_char
1008         do
1009         AC_TRY_LINK([
1010 #ifndef _XOPEN_SOURCE_EXTENDED
1011 #define _XOPEN_SOURCE_EXTENDED
1012 #endif
1013 #include <${cf_cv_ncurses_header:-curses.h}>],
1014         [void *foo = &($name['k'])],
1015         [cf_cv_curses_wacs_map=$name
1016          break])
1017         done])
1018
1019 test "$cf_cv_curses_wacs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_WACS_ARRAY,$cf_cv_curses_wacs_map,[Define to name of (n)curses wide-character array])
1020 ])dnl
1021 dnl ---------------------------------------------------------------------------
1022 dnl CF_CURSES_WACS_SYMBOLS version: 2 updated: 2012/10/06 08:57:51
1023 dnl ----------------------
1024 dnl Do a check to see if the WACS_xxx constants are defined compatibly with
1025 dnl X/Open Curses.  In particular, NetBSD's implementation of the WACS_xxx
1026 dnl constants is broken since those constants do not point to cchar_t's.
1027 AC_DEFUN([CF_CURSES_WACS_SYMBOLS],
1028 [
1029 AC_REQUIRE([CF_CURSES_WACS_MAP])
1030
1031 AC_CACHE_CHECK(for wide alternate character constants, cf_cv_curses_wacs_symbols,[
1032 cf_cv_curses_wacs_symbols=no
1033 if test "$cf_cv_curses_wacs_map" != unknown
1034 then
1035         AC_TRY_LINK([
1036 #ifndef _XOPEN_SOURCE_EXTENDED
1037 #define _XOPEN_SOURCE_EXTENDED
1038 #endif
1039 #include <${cf_cv_ncurses_header:-curses.h}>],
1040         [cchar_t *foo = WACS_PLUS;
1041          $cf_cv_curses_wacs_map['k'] = *WACS_PLUS],
1042         [cf_cv_curses_wacs_symbols=yes])
1043 else
1044         AC_TRY_LINK([
1045 #ifndef _XOPEN_SOURCE_EXTENDED
1046 #define _XOPEN_SOURCE_EXTENDED
1047 #endif
1048 #include <${cf_cv_ncurses_header:-curses.h}>],
1049         [cchar_t *foo = WACS_PLUS],
1050         [cf_cv_curses_wacs_symbols=yes])
1051 fi
1052 ])
1053
1054 test "$cf_cv_curses_wacs_symbols" != no && AC_DEFINE(CURSES_WACS_SYMBOLS,1,[Define to 1 if (n)curses supports wide-character WACS_ symbols])
1055 ])dnl
1056 dnl ---------------------------------------------------------------------------
1057 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1058 dnl ----------
1059 dnl "dirname" is not portable, so we fake it with a shell script.
1060 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1061 dnl ---------------------------------------------------------------------------
1062 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1063 dnl ---------------
1064 dnl You can always use "make -n" to see the actual options, but it's hard to
1065 dnl pick out/analyze warning messages when the compile-line is long.
1066 dnl
1067 dnl Sets:
1068 dnl     ECHO_LT - symbol to control if libtool is verbose
1069 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1070 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1071 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1072 dnl     ECHO_CC - symbol to put before any "cc" line
1073 dnl
1074 AC_DEFUN([CF_DISABLE_ECHO],[
1075 AC_MSG_CHECKING(if you want to see long compiling messages)
1076 CF_ARG_DISABLE(echo,
1077         [  --disable-echo          do not display "compiling" commands],
1078         [
1079         ECHO_LT='--silent'
1080         ECHO_LD='@echo linking [$]@;'
1081         RULE_CC='@echo compiling [$]<'
1082         SHOW_CC='@echo compiling [$]@'
1083         ECHO_CC='@'
1084 ],[
1085         ECHO_LT=''
1086         ECHO_LD=''
1087         RULE_CC=''
1088         SHOW_CC=''
1089         ECHO_CC=''
1090 ])
1091 AC_MSG_RESULT($enableval)
1092 AC_SUBST(ECHO_LT)
1093 AC_SUBST(ECHO_LD)
1094 AC_SUBST(RULE_CC)
1095 AC_SUBST(SHOW_CC)
1096 AC_SUBST(ECHO_CC)
1097 ])dnl
1098 dnl ---------------------------------------------------------------------------
1099 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1100 dnl ----------------
1101 dnl Combine no-leak checks with the libraries or tools that are used for the
1102 dnl checks.
1103 AC_DEFUN([CF_DISABLE_LEAKS],[
1104
1105 AC_REQUIRE([CF_WITH_DMALLOC])
1106 AC_REQUIRE([CF_WITH_DBMALLOC])
1107 AC_REQUIRE([CF_WITH_VALGRIND])
1108
1109 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1110 AC_ARG_ENABLE(leaks,
1111         [  --disable-leaks         test: free permanent memory, analyze leaks],
1112         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1113         : ${with_no_leaks:=no})
1114 AC_MSG_RESULT($with_no_leaks)
1115
1116 if test "$with_no_leaks" = yes ; then
1117         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1118         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1119 fi
1120 ])dnl
1121 dnl ---------------------------------------------------------------------------
1122 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1123 dnl ---------------------
1124 dnl The rpath-hack makes it simpler to build programs, particularly with the
1125 dnl *BSD ports which may have essential libraries in unusual places.  But it
1126 dnl can interfere with building an executable for the base system.  Use this
1127 dnl option in that case.
1128 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1129 [
1130 AC_MSG_CHECKING(if rpath-hack should be disabled)
1131 CF_ARG_DISABLE(rpath-hack,
1132         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1133         [cf_disable_rpath_hack=yes],
1134         [cf_disable_rpath_hack=no])
1135 AC_MSG_RESULT($cf_disable_rpath_hack)
1136 if test "$cf_disable_rpath_hack" = no ; then
1137         CF_RPATH_HACK
1138 fi
1139 ])
1140 dnl ---------------------------------------------------------------------------
1141 dnl CF_ENABLE_STRING_HACKS version: 5 updated: 2016/10/08 17:34:11
1142 dnl ----------------------
1143 dnl On a few platforms, the compiler and/or loader nags with untruthful
1144 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1145 dnl and implying that most uses of the recommended alternatives are correct.
1146 dnl
1147 dnl Factually speaking, no one has actually counted the number of uses of these
1148 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1149 dnl instances are meaningless compared to the hundreds of millions of lines of
1150 dnl existing C code.
1151 dnl
1152 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1153 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1154 dnl standard - but evolved through phases, and older implementations are likely
1155 dnl to yield surprising results, as documented in manpages on various systems.
1156 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1157 [
1158 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1159 AC_ARG_ENABLE(string-hacks,
1160         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1161         [with_string_hacks=$enableval],
1162         [with_string_hacks=no])
1163 AC_MSG_RESULT($with_string_hacks)
1164
1165 if test "x$with_string_hacks" = "xyes"; then
1166         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1167         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1168         AC_CHECK_FUNC(strlcat,[
1169                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1170                 ],[
1171                 AC_CHECK_LIB(bsd,strlcat,[
1172                         CF_ADD_LIB(bsd)
1173                         AC_CHECK_HEADERS(bsd/string.h)
1174                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1175                         ])
1176                 ])
1177         AC_CHECK_FUNCS( strlcpy snprintf )
1178 fi
1179 ])dnl
1180 dnl ---------------------------------------------------------------------------
1181 dnl CF_ENABLE_WARNINGS version: 4 updated: 2009/07/26 17:53:03
1182 dnl ------------------
1183 dnl Configure-option to enable gcc warnings
1184 AC_DEFUN([CF_ENABLE_WARNINGS],[
1185 if ( test "$GCC" = yes || test "$GXX" = yes )
1186 then
1187 AC_MSG_CHECKING(if you want to turn on gcc warnings)
1188 CF_ARG_ENABLE(warnings,
1189         [  --enable-warnings       test: turn on gcc compiler warnings],
1190         [with_warnings=yes],
1191         [with_warnings=no])
1192 AC_MSG_RESULT($with_warnings)
1193 if test "$with_warnings" = "yes"
1194 then
1195         CF_GCC_ATTRIBUTES
1196         CF_GCC_WARNINGS
1197 fi
1198 fi
1199 ])dnl
1200 dnl ---------------------------------------------------------------------------
1201 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
1202 dnl ---------------
1203 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
1204 dnl prefer a standard location, and use -L options only if we do not find the
1205 dnl library in the standard library location(s).
1206 dnl     $1 = library name
1207 dnl     $2 = library class, usually the same as library name
1208 dnl     $3 = includes
1209 dnl     $4 = code fragment to compile/link
1210 dnl     $5 = corresponding function-name
1211 dnl     $6 = flag, nonnull if failure should not cause an error-exit
1212 dnl
1213 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
1214 dnl to use a -L option.
1215 AC_DEFUN([CF_FIND_LIBRARY],
1216 [
1217         eval 'cf_cv_have_lib_'$1'=no'
1218         cf_libdir=""
1219         AC_CHECK_FUNC($5,
1220                 eval 'cf_cv_have_lib_'$1'=yes',[
1221                 cf_save_LIBS="$LIBS"
1222                 AC_MSG_CHECKING(for $5 in -l$1)
1223                 LIBS="-l$1 $LIBS"
1224                 AC_TRY_LINK([$3],[$4],
1225                         [AC_MSG_RESULT(yes)
1226                          eval 'cf_cv_have_lib_'$1'=yes'
1227                         ],
1228                         [AC_MSG_RESULT(no)
1229                         CF_LIBRARY_PATH(cf_search,$2)
1230                         for cf_libdir in $cf_search
1231                         do
1232                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
1233                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
1234                                 AC_TRY_LINK([$3],[$4],
1235                                         [AC_MSG_RESULT(yes)
1236                                          eval 'cf_cv_have_lib_'$1'=yes'
1237                                          break],
1238                                         [AC_MSG_RESULT(no)
1239                                          LIBS="$cf_save_LIBS"])
1240                         done
1241                         ])
1242                 ])
1243 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
1244 ifelse($6,,[
1245 if test $cf_found_library = no ; then
1246         AC_MSG_ERROR(Cannot link $1 library)
1247 fi
1248 ])
1249 ])dnl
1250 dnl ---------------------------------------------------------------------------
1251 dnl CF_FIND_LINKAGE version: 20 updated: 2015/04/18 08:56:57
1252 dnl ---------------
1253 dnl Find a library (specifically the linkage used in the code fragment),
1254 dnl searching for it if it is not already in the library path.
1255 dnl See also CF_ADD_SEARCHPATH.
1256 dnl
1257 dnl Parameters (4-on are optional):
1258 dnl     $1 = headers for library entrypoint
1259 dnl     $2 = code fragment for library entrypoint
1260 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1261 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1262 dnl     $5 = action to perform if not successful
1263 dnl     $6 = module name, if not the same as the library name
1264 dnl     $7 = extra libraries
1265 dnl
1266 dnl Sets these variables:
1267 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1268 dnl     $cf_cv_header_path_$3 - include-directory if needed
1269 dnl     $cf_cv_library_path_$3 - library-directory if needed
1270 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1271 AC_DEFUN([CF_FIND_LINKAGE],[
1272
1273 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1274 # will be set on completion of the AC_TRY_LINK below.
1275 cf_cv_header_path_$3=
1276 cf_cv_library_path_$3=
1277
1278 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1279
1280 cf_save_LIBS="$LIBS"
1281
1282 AC_TRY_LINK([$1],[$2],[
1283         cf_cv_find_linkage_$3=yes
1284         cf_cv_header_path_$3=/usr/include
1285         cf_cv_library_path_$3=/usr/lib
1286 ],[
1287
1288 LIBS="-l$3 $7 $cf_save_LIBS"
1289
1290 AC_TRY_LINK([$1],[$2],[
1291         cf_cv_find_linkage_$3=yes
1292         cf_cv_header_path_$3=/usr/include
1293         cf_cv_library_path_$3=/usr/lib
1294         cf_cv_library_file_$3="-l$3"
1295 ],[
1296         cf_cv_find_linkage_$3=no
1297         LIBS="$cf_save_LIBS"
1298
1299         CF_VERBOSE(find linkage for $3 library)
1300         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1301
1302         cf_save_CPPFLAGS="$CPPFLAGS"
1303         cf_test_CPPFLAGS="$CPPFLAGS"
1304
1305         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1306         for cf_cv_header_path_$3 in $cf_search
1307         do
1308                 if test -d $cf_cv_header_path_$3 ; then
1309                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1310                         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1311                         AC_TRY_COMPILE([$1],[$2],[
1312                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1313                                 cf_cv_find_linkage_$3=maybe
1314                                 cf_test_CPPFLAGS="$CPPFLAGS"
1315                                 break],[
1316                                 CPPFLAGS="$cf_save_CPPFLAGS"
1317                                 ])
1318                 fi
1319         done
1320
1321         if test "$cf_cv_find_linkage_$3" = maybe ; then
1322
1323                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1324
1325                 cf_save_LIBS="$LIBS"
1326                 cf_save_LDFLAGS="$LDFLAGS"
1327
1328                 ifelse([$6],,,[
1329                 CPPFLAGS="$cf_test_CPPFLAGS"
1330                 LIBS="-l$3 $7 $cf_save_LIBS"
1331                 AC_TRY_LINK([$1],[$2],[
1332                         CF_VERBOSE(... found $3 library in system)
1333                         cf_cv_find_linkage_$3=yes])
1334                         CPPFLAGS="$cf_save_CPPFLAGS"
1335                         LIBS="$cf_save_LIBS"
1336                         ])
1337
1338                 if test "$cf_cv_find_linkage_$3" != yes ; then
1339                         CF_LIBRARY_PATH(cf_search,$3)
1340                         for cf_cv_library_path_$3 in $cf_search
1341                         do
1342                                 if test -d $cf_cv_library_path_$3 ; then
1343                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1344                                         CPPFLAGS="$cf_test_CPPFLAGS"
1345                                         LIBS="-l$3 $7 $cf_save_LIBS"
1346                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1347                                         AC_TRY_LINK([$1],[$2],[
1348                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1349                                         cf_cv_find_linkage_$3=yes
1350                                         cf_cv_library_file_$3="-l$3"
1351                                         break],[
1352                                         CPPFLAGS="$cf_save_CPPFLAGS"
1353                                         LIBS="$cf_save_LIBS"
1354                                         LDFLAGS="$cf_save_LDFLAGS"
1355                                         ])
1356                                 fi
1357                         done
1358                         CPPFLAGS="$cf_save_CPPFLAGS"
1359                         LDFLAGS="$cf_save_LDFLAGS"
1360                 fi
1361
1362         else
1363                 cf_cv_find_linkage_$3=no
1364         fi
1365         ],$7)
1366 ])
1367
1368 LIBS="$cf_save_LIBS"
1369
1370 if test "$cf_cv_find_linkage_$3" = yes ; then
1371 ifelse([$4],,[
1372         CF_ADD_INCDIR($cf_cv_header_path_$3)
1373         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1374         CF_ADD_LIB($3)
1375 ],[$4])
1376 else
1377 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1378 fi
1379 ])dnl
1380 dnl ---------------------------------------------------------------------------
1381 dnl CF_FUNC_CURSES_VERSION version: 7 updated: 2017/05/10 18:31:29
1382 dnl ----------------------
1383 dnl Solaris has a data item 'curses_version', which confuses AC_CHECK_FUNCS.
1384 dnl It's a character string "SVR4", not documented.
1385 AC_DEFUN([CF_FUNC_CURSES_VERSION],
1386 [
1387 AC_CACHE_CHECK(for function curses_version, cf_cv_func_curses_version,[
1388 AC_TRY_RUN([
1389 #include <${cf_cv_ncurses_header:-curses.h}>
1390 int main(void)
1391 {
1392         char temp[1024];
1393         sprintf(temp, "%s\n", curses_version());
1394         ${cf_cv_main_return:-return}(0);
1395 }]
1396 ,[cf_cv_func_curses_version=yes]
1397 ,[cf_cv_func_curses_version=no]
1398 ,[cf_cv_func_curses_version=unknown])
1399 rm -f core])
1400 test "$cf_cv_func_curses_version" = yes && AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 if we have curses_version function])
1401 ])
1402 dnl ---------------------------------------------------------------------------
1403 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
1404 dnl ---------------
1405 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1406 dnl "util" library as well.
1407 AC_DEFUN([CF_FUNC_OPENPTY],
1408 [
1409 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1410 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1411         cf_save_LIBS="$LIBS"
1412         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
1413         for cf_header in pty.h libutil.h util.h
1414         do
1415         AC_TRY_LINK([
1416 #include <$cf_header>
1417 ],[
1418         int x = openpty((int *)0, (int *)0, (char *)0,
1419                                    (struct termios *)0, (struct winsize *)0);
1420 ],[
1421                 cf_cv_func_openpty=$cf_header
1422                 break
1423 ],[
1424                 cf_cv_func_openpty=no
1425 ])
1426         done
1427         LIBS="$cf_save_LIBS"
1428 ])
1429 ])dnl
1430 dnl ---------------------------------------------------------------------------
1431 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
1432 dnl -----------------
1433 dnl Test for availability of useful gcc __attribute__ directives to quiet
1434 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1435 dnl to documentation, unrecognized directives cause older compilers to barf.
1436 AC_DEFUN([CF_GCC_ATTRIBUTES],
1437 [
1438 if test "$GCC" = yes
1439 then
1440 cat > conftest.i <<EOF
1441 #ifndef GCC_PRINTF
1442 #define GCC_PRINTF 0
1443 #endif
1444 #ifndef GCC_SCANF
1445 #define GCC_SCANF 0
1446 #endif
1447 #ifndef GCC_NORETURN
1448 #define GCC_NORETURN /* nothing */
1449 #endif
1450 #ifndef GCC_UNUSED
1451 #define GCC_UNUSED /* nothing */
1452 #endif
1453 EOF
1454 if test "$GCC" = yes
1455 then
1456         AC_CHECKING([for $CC __attribute__ directives])
1457 cat > conftest.$ac_ext <<EOF
1458 #line __oline__ "${as_me:-configure}"
1459 #include "confdefs.h"
1460 #include "conftest.h"
1461 #include "conftest.i"
1462 #if     GCC_PRINTF
1463 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1464 #else
1465 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1466 #endif
1467 #if     GCC_SCANF
1468 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1469 #else
1470 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1471 #endif
1472 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1473 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1474 extern void foo(void) GCC_NORETURN;
1475 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1476 EOF
1477         cf_printf_attribute=no
1478         cf_scanf_attribute=no
1479         for cf_attribute in scanf printf unused noreturn
1480         do
1481                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1482                 cf_directive="__attribute__(($cf_attribute))"
1483                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1484
1485                 case $cf_attribute in
1486                 (printf)
1487                         cf_printf_attribute=yes
1488                         cat >conftest.h <<EOF
1489 #define GCC_$cf_ATTRIBUTE 1
1490 EOF
1491                         ;;
1492                 (scanf)
1493                         cf_scanf_attribute=yes
1494                         cat >conftest.h <<EOF
1495 #define GCC_$cf_ATTRIBUTE 1
1496 EOF
1497                         ;;
1498                 (*)
1499                         cat >conftest.h <<EOF
1500 #define GCC_$cf_ATTRIBUTE $cf_directive
1501 EOF
1502                         ;;
1503                 esac
1504
1505                 if AC_TRY_EVAL(ac_compile); then
1506                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1507                         cat conftest.h >>confdefs.h
1508                         case $cf_attribute in
1509                         (noreturn)
1510                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1511                                 ;;
1512                         (printf)
1513                                 cf_value='/* nothing */'
1514                                 if test "$cf_printf_attribute" != no ; then
1515                                         cf_value='__attribute__((format(printf,fmt,var)))'
1516                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1517                                 fi
1518                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1519                                 ;;
1520                         (scanf)
1521                                 cf_value='/* nothing */'
1522                                 if test "$cf_scanf_attribute" != no ; then
1523                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1524                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1525                                 fi
1526                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1527                                 ;;
1528                         (unused)
1529                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1530                                 ;;
1531                         esac
1532                 fi
1533         done
1534 else
1535         fgrep define conftest.i >>confdefs.h
1536 fi
1537 rm -rf conftest*
1538 fi
1539 ])dnl
1540 dnl ---------------------------------------------------------------------------
1541 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1542 dnl --------------
1543 dnl Find version of gcc
1544 AC_DEFUN([CF_GCC_VERSION],[
1545 AC_REQUIRE([AC_PROG_CC])
1546 GCC_VERSION=none
1547 if test "$GCC" = yes ; then
1548         AC_MSG_CHECKING(version of $CC)
1549         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1550         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1551         AC_MSG_RESULT($GCC_VERSION)
1552 fi
1553 ])dnl
1554 dnl ---------------------------------------------------------------------------
1555 dnl CF_GCC_WARNINGS version: 32 updated: 2015/04/12 15:39:00
1556 dnl ---------------
1557 dnl Check if the compiler supports useful warning options.  There's a few that
1558 dnl we don't use, simply because they're too noisy:
1559 dnl
1560 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1561 dnl     -Wredundant-decls (system headers make this too noisy)
1562 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1563 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1564 dnl             is enabled for ncurses using "--enable-const".
1565 dnl     -pedantic
1566 dnl
1567 dnl Parameter:
1568 dnl     $1 is an optional list of gcc warning flags that a particular
1569 dnl             application might want to use, e.g., "no-unused" for
1570 dnl             -Wno-unused
1571 dnl Special:
1572 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1573 dnl
1574 AC_DEFUN([CF_GCC_WARNINGS],
1575 [
1576 AC_REQUIRE([CF_GCC_VERSION])
1577 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1578 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1579
1580 cat > conftest.$ac_ext <<EOF
1581 #line __oline__ "${as_me:-configure}"
1582 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1583 EOF
1584
1585 if test "$INTEL_COMPILER" = yes
1586 then
1587 # The "-wdXXX" options suppress warnings:
1588 # remark #1419: external declaration in primary source file
1589 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1590 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1591 # remark #193: zero used for undefined preprocessing identifier
1592 # remark #593: variable "curs_sb_left_arrow" was set but never used
1593 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1594 # remark #869: parameter "tw" was never referenced
1595 # remark #981: operands are evaluated in unspecified order
1596 # warning #279: controlling expression is constant
1597
1598         AC_CHECKING([for $CC warning options])
1599         cf_save_CFLAGS="$CFLAGS"
1600         EXTRA_CFLAGS="-Wall"
1601         for cf_opt in \
1602                 wd1419 \
1603                 wd1683 \
1604                 wd1684 \
1605                 wd193 \
1606                 wd593 \
1607                 wd279 \
1608                 wd810 \
1609                 wd869 \
1610                 wd981
1611         do
1612                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1613                 if AC_TRY_EVAL(ac_compile); then
1614                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1615                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1616                 fi
1617         done
1618         CFLAGS="$cf_save_CFLAGS"
1619
1620 elif test "$GCC" = yes
1621 then
1622         AC_CHECKING([for $CC warning options])
1623         cf_save_CFLAGS="$CFLAGS"
1624         EXTRA_CFLAGS=
1625         cf_warn_CONST=""
1626         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1627         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1628         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1629         for cf_opt in W Wall \
1630                 Wbad-function-cast \
1631                 Wcast-align \
1632                 Wcast-qual \
1633                 Wdeclaration-after-statement \
1634                 Wextra \
1635                 Winline \
1636                 Wmissing-declarations \
1637                 Wmissing-prototypes \
1638                 Wnested-externs \
1639                 Wpointer-arith \
1640                 Wshadow \
1641                 Wstrict-prototypes \
1642                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
1643         do
1644                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1645                 if AC_TRY_EVAL(ac_compile); then
1646                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1647                         case $cf_opt in
1648                         (Wcast-qual)
1649                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1650                                 ;;
1651                         (Winline)
1652                                 case $GCC_VERSION in
1653                                 ([[34]].*)
1654                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1655                                         continue;;
1656                                 esac
1657                                 ;;
1658                         (Wpointer-arith)
1659                                 case $GCC_VERSION in
1660                                 ([[12]].*)
1661                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1662                                         continue;;
1663                                 esac
1664                                 ;;
1665                         esac
1666                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1667                 fi
1668         done
1669         CFLAGS="$cf_save_CFLAGS"
1670 fi
1671 rm -rf conftest*
1672
1673 AC_SUBST(EXTRA_CFLAGS)
1674 ])dnl
1675 dnl ---------------------------------------------------------------------------
1676 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
1677 dnl ----------------
1678 dnl Check for getopt's variables which are commonly defined in stdlib.h,
1679 dnl unistd.h or (nonstandard) in getopt.h
1680 AC_DEFUN([CF_GETOPT_HEADER],
1681 [
1682 AC_HAVE_HEADERS(unistd.h getopt.h)
1683 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
1684 cf_cv_getopt_header=none
1685 for cf_header in stdio.h stdlib.h unistd.h getopt.h
1686 do
1687 AC_TRY_COMPILE([
1688 #include <$cf_header>],
1689 [int x = optind; char *y = optarg],
1690 [cf_cv_getopt_header=$cf_header
1691  break])
1692 done
1693 ])
1694 if test $cf_cv_getopt_header != none ; then
1695         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
1696 fi
1697 if test $cf_cv_getopt_header = getopt.h ; then
1698         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
1699 fi
1700 ])dnl
1701 dnl ---------------------------------------------------------------------------
1702 dnl CF_GNU_SOURCE version: 7 updated: 2016/08/05 05:15:37
1703 dnl -------------
1704 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1705 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1706 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1707 dnl since it is interwoven with GNU extensions.
1708 dnl
1709 dnl Well, yes we could work around it...
1710 AC_DEFUN([CF_GNU_SOURCE],
1711 [
1712 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1713 AC_TRY_COMPILE([#include <sys/types.h>],[
1714 #ifndef _XOPEN_SOURCE
1715 make an error
1716 #endif],
1717         [cf_cv_gnu_source=no],
1718         [cf_save="$CPPFLAGS"
1719          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1720          AC_TRY_COMPILE([#include <sys/types.h>],[
1721 #ifdef _XOPEN_SOURCE
1722 make an error
1723 #endif],
1724         [cf_cv_gnu_source=no],
1725         [cf_cv_gnu_source=yes])
1726         CPPFLAGS="$cf_save"
1727         ])
1728 ])
1729
1730 if test "$cf_cv_gnu_source" = yes
1731 then
1732 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
1733 CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1734         AC_TRY_COMPILE([#include <sys/types.h>],[
1735 #ifdef _DEFAULT_SOURCE
1736 make an error
1737 #endif],
1738                 [cf_cv_default_source=no],
1739                 [cf_cv_default_source=yes])
1740         ])
1741 test "$cf_cv_default_source" = yes && CPPFLAGS="$CPPFLAGS -D_DEFAULT_SOURCE"
1742 fi
1743 ])dnl
1744 dnl ---------------------------------------------------------------------------
1745 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
1746 dnl --------------
1747 dnl Construct a search-list of directories for a nonstandard header-file
1748 dnl
1749 dnl Parameters
1750 dnl     $1 = the variable to return as result
1751 dnl     $2 = the package name
1752 AC_DEFUN([CF_HEADER_PATH],
1753 [
1754 $1=
1755
1756 # collect the current set of include-directories from compiler flags
1757 cf_header_path_list=""
1758 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1759         for cf_header_path in $CPPFLAGS $CFLAGS
1760         do
1761                 case $cf_header_path in
1762                 (-I*)
1763                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1764                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1765                         cf_header_path_list="$cf_header_path_list [$]$1"
1766                         ;;
1767                 esac
1768         done
1769 fi
1770
1771 # add the variations for the package we are looking for
1772 CF_SUBDIR_PATH($1,$2,include)
1773
1774 test "$includedir" != NONE && \
1775 test "$includedir" != "/usr/include" && \
1776 test -d "$includedir" && {
1777         test -d $includedir &&    $1="[$]$1 $includedir"
1778         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1779 }
1780
1781 test "$oldincludedir" != NONE && \
1782 test "$oldincludedir" != "/usr/include" && \
1783 test -d "$oldincludedir" && {
1784         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1785         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1786 }
1787
1788 $1="[$]$1 $cf_header_path_list"
1789 ])dnl
1790 dnl ---------------------------------------------------------------------------
1791 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
1792 dnl ---------------
1793 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1794 AC_DEFUN([CF_HELP_MESSAGE],
1795 [AC_DIVERT_HELP([$1])dnl
1796 ])dnl
1797 dnl ---------------------------------------------------------------------------
1798 dnl CF_INHERIT_SCRIPT version: 2 updated: 2003/03/01 23:50:42
1799 dnl -----------------
1800 dnl If we do not have a given script, look for it in the parent directory.
1801 AC_DEFUN([CF_INHERIT_SCRIPT],
1802 [
1803 test -f $1 || ( test -f ../$1 && cp ../$1 ./ )
1804 ])dnl
1805 dnl ---------------------------------------------------------------------------
1806 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
1807 dnl -----------------
1808 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1809 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1810 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1811 dnl
1812 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1813 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1814 dnl the wrappers for gcc and g++ warnings.
1815 dnl
1816 dnl $1 = GCC (default) or GXX
1817 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1818 dnl $3 = CFLAGS (default) or CXXFLAGS
1819 AC_DEFUN([CF_INTEL_COMPILER],[
1820 AC_REQUIRE([AC_CANONICAL_HOST])
1821 ifelse([$2],,INTEL_COMPILER,[$2])=no
1822
1823 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1824         case $host_os in
1825         (linux*|gnu*)
1826                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1827                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1828                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1829                 AC_TRY_COMPILE([],[
1830 #ifdef __INTEL_COMPILER
1831 #else
1832 make an error
1833 #endif
1834 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1835 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
1836 ],[])
1837                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1838                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1839                 ;;
1840         esac
1841 fi
1842 ])dnl
1843 dnl ---------------------------------------------------------------------------
1844 dnl CF_LD_RPATH_OPT version: 7 updated: 2016/02/20 18:01:19
1845 dnl ---------------
1846 dnl For the given system and compiler, find the compiler flags to pass to the
1847 dnl loader to use the "rpath" feature.
1848 AC_DEFUN([CF_LD_RPATH_OPT],
1849 [
1850 AC_REQUIRE([CF_CHECK_CACHE])
1851
1852 LD_RPATH_OPT=
1853 AC_MSG_CHECKING(for an rpath option)
1854 case $cf_cv_system_name in
1855 (irix*)
1856         if test "$GCC" = yes; then
1857                 LD_RPATH_OPT="-Wl,-rpath,"
1858         else
1859                 LD_RPATH_OPT="-rpath "
1860         fi
1861         ;;
1862 (linux*|gnu*|k*bsd*-gnu|freebsd*)
1863         LD_RPATH_OPT="-Wl,-rpath,"
1864         ;;
1865 (openbsd[[2-9]].*|mirbsd*)
1866         LD_RPATH_OPT="-Wl,-rpath,"
1867         ;;
1868 (dragonfly*)
1869         LD_RPATH_OPT="-rpath "
1870         ;;
1871 (netbsd*)
1872         LD_RPATH_OPT="-Wl,-rpath,"
1873         ;;
1874 (osf*|mls+*)
1875         LD_RPATH_OPT="-rpath "
1876         ;;
1877 (solaris2*)
1878         LD_RPATH_OPT="-R"
1879         ;;
1880 (*)
1881         ;;
1882 esac
1883 AC_MSG_RESULT($LD_RPATH_OPT)
1884
1885 case "x$LD_RPATH_OPT" in
1886 (x-R*)
1887         AC_MSG_CHECKING(if we need a space after rpath option)
1888         cf_save_LIBS="$LIBS"
1889         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1890         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1891         LIBS="$cf_save_LIBS"
1892         AC_MSG_RESULT($cf_rpath_space)
1893         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1894         ;;
1895 esac
1896 ])dnl
1897 dnl ---------------------------------------------------------------------------
1898 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
1899 dnl ---------------
1900 dnl Construct a search-list of directories for a nonstandard library-file
1901 dnl
1902 dnl Parameters
1903 dnl     $1 = the variable to return as result
1904 dnl     $2 = the package name
1905 AC_DEFUN([CF_LIBRARY_PATH],
1906 [
1907 $1=
1908 cf_library_path_list=""
1909 if test -n "${LDFLAGS}${LIBS}" ; then
1910         for cf_library_path in $LDFLAGS $LIBS
1911         do
1912                 case $cf_library_path in
1913                 (-L*)
1914                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1915                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1916                         cf_library_path_list="$cf_library_path_list [$]$1"
1917                         ;;
1918                 esac
1919         done
1920 fi
1921
1922 CF_SUBDIR_PATH($1,$2,lib)
1923
1924 $1="$cf_library_path_list [$]$1"
1925 ])dnl
1926 dnl ---------------------------------------------------------------------------
1927 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
1928 dnl ------------
1929 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
1930 dnl a monocase filesystem.
1931 AC_DEFUN([CF_MAKE_TAGS],[
1932 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
1933
1934 AC_CHECK_PROGS(CTAGS, exctags ctags)
1935 AC_CHECK_PROGS(ETAGS, exetags etags)
1936
1937 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
1938
1939 if test "$cf_cv_mixedcase" = yes ; then
1940         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
1941 else
1942         MAKE_UPPER_TAGS=no
1943 fi
1944
1945 if test "$MAKE_UPPER_TAGS" = yes ; then
1946         MAKE_UPPER_TAGS=
1947 else
1948         MAKE_UPPER_TAGS="#"
1949 fi
1950
1951 if test "$MAKE_LOWER_TAGS" = yes ; then
1952         MAKE_LOWER_TAGS=
1953 else
1954         MAKE_LOWER_TAGS="#"
1955 fi
1956
1957 AC_SUBST(CTAGS)
1958 AC_SUBST(ETAGS)
1959
1960 AC_SUBST(MAKE_UPPER_TAGS)
1961 AC_SUBST(MAKE_LOWER_TAGS)
1962 ])dnl
1963 dnl ---------------------------------------------------------------------------
1964 dnl CF_MATH_LIB version: 9 updated: 2017/01/21 11:06:25
1965 dnl -----------
1966 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
1967 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
1968 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
1969 AC_DEFUN([CF_MATH_LIB],
1970 [
1971 AC_CACHE_CHECK(if -lm needed for math functions,
1972         cf_cv_need_libm,[
1973         AC_TRY_LINK([
1974         #include <stdio.h>
1975         #include <stdlib.h>
1976         #include <math.h>
1977         ],
1978         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
1979         [cf_cv_need_libm=no],
1980         [cf_cv_need_libm=yes])])
1981 if test "$cf_cv_need_libm" = yes
1982 then
1983 ifelse($1,,[
1984         CF_ADD_LIB(m)
1985 ],[$1=-lm])
1986 fi
1987 ])
1988 dnl ---------------------------------------------------------------------------
1989 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
1990 dnl ----------------------
1991 dnl Check if the file-system supports mixed-case filenames.  If we're able to
1992 dnl create a lowercase name and see it as uppercase, it doesn't support that.
1993 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
1994 [
1995 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
1996 if test "$cross_compiling" = yes ; then
1997         case $target_alias in
1998         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
1999                 cf_cv_mixedcase=no
2000                 ;;
2001         (*)
2002                 cf_cv_mixedcase=yes
2003                 ;;
2004         esac
2005 else
2006         rm -f conftest CONFTEST
2007         echo test >conftest
2008         if test -f CONFTEST ; then
2009                 cf_cv_mixedcase=no
2010         else
2011                 cf_cv_mixedcase=yes
2012         fi
2013         rm -f conftest CONFTEST
2014 fi
2015 ])
2016 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2017 ])dnl
2018 dnl ---------------------------------------------------------------------------
2019 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2020 dnl ----------
2021 dnl Write a debug message to config.log, along with the line number in the
2022 dnl configure script.
2023 AC_DEFUN([CF_MSG_LOG],[
2024 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2025 ])dnl
2026 dnl ---------------------------------------------------------------------------
2027 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2028 dnl -------------------
2029 dnl Check if we can compile with ncurses' header file
2030 dnl $1 is the cache variable to set
2031 dnl $2 is the header-file to include
2032 dnl $3 is the root name (ncurses or ncursesw)
2033 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2034         AC_TRY_COMPILE([
2035 ]ifelse($3,ncursesw,[
2036 #define _XOPEN_SOURCE_EXTENDED
2037 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2038 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2039 ])[
2040 #include <$2>],[
2041 #ifdef NCURSES_VERSION
2042 ]ifelse($3,ncursesw,[
2043 #ifndef WACS_BSSB
2044         make an error
2045 #endif
2046 ])[
2047 printf("%s\n", NCURSES_VERSION);
2048 #else
2049 #ifdef __NCURSES_H
2050 printf("old\n");
2051 #else
2052         make an error
2053 #endif
2054 #endif
2055         ]
2056         ,[$1=$2]
2057         ,[$1=no])
2058 ])dnl
2059 dnl ---------------------------------------------------------------------------
2060 dnl CF_NCURSES_CONFIG version: 18 updated: 2017/07/23 18:30:00
2061 dnl -----------------
2062 dnl Tie together the configure-script macros for ncurses, preferring these in
2063 dnl order:
2064 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2065 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2066 dnl c) just plain libraries
2067 dnl
2068 dnl $1 is the root library name (default: "ncurses")
2069 AC_DEFUN([CF_NCURSES_CONFIG],[
2070 AC_REQUIRE([CF_PKG_CONFIG])
2071 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2072 cf_have_ncuconfig=no
2073
2074 if test "x${PKG_CONFIG:=none}" != xnone; then
2075         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2076         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2077                 AC_MSG_RESULT(yes)
2078
2079                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2080                 cf_have_ncuconfig=unknown
2081
2082                 cf_save_CPPFLAGS="$CPPFLAGS"
2083                 cf_save_LIBS="$LIBS"
2084
2085                 CPPFLAGS="$CPPFLAGS `$PKG_CONFIG --cflags $cf_ncuconfig_root`"
2086                 CF_ADD_LIBS(`$PKG_CONFIG --libs $cf_ncuconfig_root`)
2087
2088                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2089                         [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2090                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2091                                 int main(void)
2092                                 { char *xx = curses_version(); return (xx == 0); }],
2093                                 [cf_have_ncuconfig=yes],
2094                                 [cf_have_ncuconfig=no],
2095                                 [cf_have_ncuconfig=maybe])],
2096                         [cf_have_ncuconfig=no])
2097                 AC_MSG_RESULT($cf_have_ncuconfig)
2098                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
2099                 if test "$cf_have_ncuconfig" != "yes"
2100                 then
2101                         CPPFLAGS="$cf_save_CPPFLAGS"
2102                         LIBS="$cf_save_LIBS"
2103                         NCURSES_CONFIG_PKG=none
2104                 else
2105                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2106                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2107                 fi
2108                 CF_TERM_HEADER
2109
2110         else
2111                 AC_MSG_RESULT(no)
2112                 NCURSES_CONFIG_PKG=none
2113         fi
2114 else
2115         NCURSES_CONFIG_PKG=none
2116 fi
2117
2118 if test "x$cf_have_ncuconfig" = "xno"; then
2119         echo "Looking for ${cf_ncuconfig_root}-config"
2120
2121         CF_ACVERSION_CHECK(2.52,
2122                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncuconfig_root}-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2123                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncuconfig_root}-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2124
2125         if test "$NCURSES_CONFIG" != none ; then
2126
2127                 CPPFLAGS="$CPPFLAGS `$NCURSES_CONFIG --cflags`"
2128                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2129
2130                 # even with config script, some packages use no-override for curses.h
2131                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2132
2133                 dnl like CF_NCURSES_CPPFLAGS
2134                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2135
2136                 dnl like CF_NCURSES_LIBS
2137                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2138                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2139
2140                 dnl like CF_NCURSES_VERSION
2141                 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2142
2143         else
2144
2145                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2146                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2147
2148         fi
2149 else
2150         NCURSES_CONFIG=none
2151 fi
2152 ])dnl
2153 dnl ---------------------------------------------------------------------------
2154 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
2155 dnl -------------------
2156 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2157 dnl the CPPFLAGS variable so we can include its header.
2158 dnl
2159 dnl The header files may be installed as either curses.h, or ncurses.h (would
2160 dnl be obsolete, except that some packagers prefer this name to distinguish it
2161 dnl from a "native" curses implementation).  If not installed for overwrite,
2162 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2163 dnl /usr/include/ncurses), but someone may have installed overwriting the
2164 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2165 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2166 dnl the header.
2167 dnl
2168 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2169 dnl is already in the include-path, don't even bother with this, since we cannot
2170 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2171 dnl
2172 dnl The optional parameter gives the root name of the library, in case it is
2173 dnl not installed as the default curses library.  That is how the
2174 dnl wide-character version of ncurses is installed.
2175 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2176 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2177
2178 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2179 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2180
2181 test -n "$cf_cv_curses_dir" && \
2182 test "$cf_cv_curses_dir" != "no" && { \
2183   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2184 }
2185
2186 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2187         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2188         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2189         for cf_header in $cf_header_list
2190         do
2191                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2192                 test "$cf_cv_ncurses_h" != no && break
2193         done
2194 ])
2195
2196 CF_NCURSES_HEADER
2197 CF_TERM_HEADER
2198
2199 # some applications need this, but should check for NCURSES_VERSION
2200 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2201
2202 CF_NCURSES_VERSION
2203 ])dnl
2204 dnl ---------------------------------------------------------------------------
2205 dnl CF_NCURSES_EXT_FUNCS version: 4 updated: 2012/10/06 16:39:58
2206 dnl --------------------
2207 dnl Since 2007/11/17, ncurses has defined NCURSES_EXT_FUNCS; earlier versions
2208 dnl may provide these functions.  Define the symbol if it is not defined, and
2209 dnl if it is valid.
2210 AC_DEFUN([CF_NCURSES_EXT_FUNCS],
2211 [
2212 AC_CACHE_CHECK(for ncurses extended functions,cf_cv_ncurses_ext_funcs,[
2213 AC_TRY_COMPILE([
2214 #include <${cf_cv_ncurses_header:-curses.h}>],
2215 [
2216 int x = NCURSES_EXT_FUNCS
2217 ],[cf_cv_ncurses_ext_funcs=defined],[
2218 AC_TRY_LINK([
2219 #include <${cf_cv_ncurses_header:-curses.h}>],
2220 [
2221         (void) assume_default_colors (0, 0);
2222         (void) curses_version ();
2223         (void) define_key (0, 0);
2224         (void) is_term_resized (0, 0);
2225         (void) key_defined (0);
2226         (void) keybound (0, 0);
2227         (void) keyok (0, 0);
2228         (void) resize_term (0, 0);
2229         (void) resizeterm (0, 0);
2230         (void) use_default_colors ();
2231         (void) use_extended_names (0);
2232         (void) wresize (0, 0, 0);],
2233         [cf_cv_ncurses_ext_funcs=yes],
2234         [cf_cv_ncurses_ext_funcs=no])
2235 ])
2236 ])
2237 test "$cf_cv_ncurses_ext_funcs" = yes && AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 if we have ncurses extensions])
2238 ])dnl
2239 dnl ---------------------------------------------------------------------------
2240 dnl CF_NCURSES_HEADER version: 4 updated: 2015/04/15 19:08:48
2241 dnl -----------------
2242 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2243 dnl variations of ncurses' installs.
2244 dnl
2245 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2246 AC_DEFUN([CF_NCURSES_HEADER],[
2247
2248 if test "$cf_cv_ncurses_h" != no ; then
2249         cf_cv_ncurses_header=$cf_cv_ncurses_h
2250 else
2251
2252 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2253         test -n "$verbose" && echo
2254         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2255         test -n "$verbose" && echo search path $cf_search
2256         cf_save2_CPPFLAGS="$CPPFLAGS"
2257         for cf_incdir in $cf_search
2258         do
2259                 CF_ADD_INCDIR($cf_incdir)
2260                 for cf_header in \
2261                         ncurses.h \
2262                         curses.h
2263                 do
2264                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2265                         if test "$cf_cv_ncurses_h2" != no ; then
2266                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2267                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2268                                 break
2269                         fi
2270                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2271                 done
2272                 CPPFLAGS="$cf_save2_CPPFLAGS"
2273                 test "$cf_cv_ncurses_h2" != no && break
2274         done
2275         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2276         ])
2277
2278         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2279         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2280         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2281                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2282         fi
2283         CF_ADD_INCDIR($cf_1st_incdir)
2284
2285 fi
2286
2287 # Set definitions to allow ifdef'ing for ncurses.h
2288
2289 case $cf_cv_ncurses_header in
2290 (*ncurses.h)
2291         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2292         ;;
2293 esac
2294
2295 case $cf_cv_ncurses_header in
2296 (ncurses/curses.h|ncurses/ncurses.h)
2297         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2298         ;;
2299 (ncursesw/curses.h|ncursesw/ncurses.h)
2300         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2301         ;;
2302 esac
2303
2304 ])dnl
2305 dnl ---------------------------------------------------------------------------
2306 dnl CF_NCURSES_LIBS version: 17 updated: 2015/04/15 19:08:48
2307 dnl ---------------
2308 dnl Look for the ncurses library.  This is a little complicated on Linux,
2309 dnl because it may be linked with the gpm (general purpose mouse) library.
2310 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2311 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2312 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2313 dnl and the linker will record a dependency.
2314 dnl
2315 dnl The optional parameter gives the root name of the library, in case it is
2316 dnl not installed as the default curses library.  That is how the
2317 dnl wide-character version of ncurses is installed.
2318 AC_DEFUN([CF_NCURSES_LIBS],
2319 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2320
2321 cf_nculib_root=ifelse($1,,ncurses,$1)
2322         # This works, except for the special case where we find gpm, but
2323         # ncurses is in a nonstandard location via $LIBS, and we really want
2324         # to link gpm.
2325 cf_ncurses_LIBS=""
2326 cf_ncurses_SAVE="$LIBS"
2327 AC_CHECK_LIB(gpm,Gpm_Open,
2328         [AC_CHECK_LIB(gpm,initscr,
2329                 [LIBS="$cf_ncurses_SAVE"],
2330                 [cf_ncurses_LIBS="-lgpm"])])
2331
2332 case $host_os in
2333 (freebsd*)
2334         # This is only necessary if you are linking against an obsolete
2335         # version of ncurses (but it should do no harm, since it's static).
2336         if test "$cf_nculib_root" = ncurses ; then
2337                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2338         fi
2339         ;;
2340 esac
2341
2342 CF_ADD_LIBS($cf_ncurses_LIBS)
2343
2344 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2345 then
2346         CF_ADD_LIBS(-l$cf_nculib_root)
2347 else
2348         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2349                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2350                 [initscr()],
2351                 initscr)
2352 fi
2353
2354 if test -n "$cf_ncurses_LIBS" ; then
2355         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2356         cf_ncurses_SAVE="$LIBS"
2357         for p in $cf_ncurses_LIBS ; do
2358                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2359                 if test "$q" != "$LIBS" ; then
2360                         LIBS="$q"
2361                 fi
2362         done
2363         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2364                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2365                 [AC_MSG_RESULT(yes)],
2366                 [AC_MSG_RESULT(no)
2367                  LIBS="$cf_ncurses_SAVE"])
2368 fi
2369
2370 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2371 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2372 ])dnl
2373 dnl ---------------------------------------------------------------------------
2374 dnl CF_NCURSES_PTHREADS version: 2 updated: 2016/04/22 05:07:41
2375 dnl -------------------
2376 dnl Use this followup check to ensure that we link with pthreads if ncurses
2377 dnl uses it.
2378 AC_DEFUN([CF_NCURSES_PTHREADS],[
2379 : ${cf_nculib_root:=ifelse($1,,ncurses,$1)}
2380 AC_CHECK_LIB($cf_nculib_root,_nc_init_pthreads,
2381         cf_cv_ncurses_pthreads=yes,
2382         cf_cv_ncurses_pthreads=no)
2383 if test "$cf_cv_ncurses_pthreads" = yes
2384 then
2385         CF_ADD_LIBS(-lpthread)
2386 fi
2387 ])dnl
2388 dnl ---------------------------------------------------------------------------
2389 dnl CF_NCURSES_VERSION version: 15 updated: 2017/05/09 19:26:10
2390 dnl ------------------
2391 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2392 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2393 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2394 AC_DEFUN([CF_NCURSES_VERSION],
2395 [
2396 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2397 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2398         cf_cv_ncurses_version=no
2399         cf_tempfile=out$$
2400         rm -f $cf_tempfile
2401         AC_TRY_RUN([
2402 #include <${cf_cv_ncurses_header:-curses.h}>
2403 #include <stdio.h>
2404 int main(void)
2405 {
2406         FILE *fp = fopen("$cf_tempfile", "w");
2407 #ifdef NCURSES_VERSION
2408 # ifdef NCURSES_VERSION_PATCH
2409         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2410 # else
2411         fprintf(fp, "%s\n", NCURSES_VERSION);
2412 # endif
2413 #else
2414 # ifdef __NCURSES_H
2415         fprintf(fp, "old\n");
2416 # else
2417         make an error
2418 # endif
2419 #endif
2420         ${cf_cv_main_return:-return}(0);
2421 }],[
2422         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2423
2424         # This will not work if the preprocessor splits the line after the
2425         # Autoconf token.  The 'unproto' program does that.
2426         cat > conftest.$ac_ext <<EOF
2427 #include <${cf_cv_ncurses_header:-curses.h}>
2428 #undef Autoconf
2429 #ifdef NCURSES_VERSION
2430 Autoconf NCURSES_VERSION
2431 #else
2432 #ifdef __NCURSES_H
2433 Autoconf "old"
2434 #endif
2435 ;
2436 #endif
2437 EOF
2438         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2439         AC_TRY_EVAL(cf_try)
2440         if test -f conftest.out ; then
2441                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2442                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2443                 rm -f conftest.out
2444         fi
2445 ])
2446         rm -f $cf_tempfile
2447 ])
2448 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2449 ])dnl
2450 dnl ---------------------------------------------------------------------------
2451 dnl CF_NCURSES_WRAP_PREFIX version: 1 updated: 2009/03/28 16:08:10
2452 dnl ----------------------
2453 dnl Check for ncurses "wrap-prefix" used for public variables which have been
2454 dnl wrapped with a function to help with concurrency control.
2455 AC_DEFUN([CF_NCURSES_WRAP_PREFIX],
2456 [
2457 AC_MSG_CHECKING(for ncurses wrap-prefix)
2458 AC_ARG_WITH(ncurses-wrap-prefix,
2459         [  --with-ncurses-wrap-prefix naming-prefix for ncurses wrapped-variables],
2460         [NCURSES_WRAP_PREFIX=$withval],
2461         [NCURSES_WRAP_PREFIX=_nc_])
2462 AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
2463
2464 AC_SUBST(NCURSES_WRAP_PREFIX)
2465 ])
2466 dnl ---------------------------------------------------------------------------
2467 dnl CF_NETBSD_FORM_H version: 2 updated: 2012/10/06 16:39:58
2468 dnl ----------------
2469 dnl Check for NetBSD's form.h, which is incompatible with SVr4 and ncurses.
2470 dnl Some workarounds are needed in client programs to allow them to compile.
2471 AC_DEFUN([CF_NETBSD_FORM_H],[
2472 AC_CACHE_CHECK(for NetBSD form.h,cf_cv_netbsd_form_h,[
2473 AC_TRY_COMPILE([
2474 #include <${cf_cv_ncurses_header:-curses.h}>
2475 #include <form.h>
2476 ],[
2477         FORM *form;
2478         int y = current_field(form)->cursor_ypos;
2479         int x = current_field(form)->cursor_xpos;
2480 ],[cf_cv_netbsd_form_h=yes
2481 ],[cf_cv_netbsd_form_h=no])
2482 ])
2483
2484 test "$cf_cv_netbsd_form_h" = yes && AC_DEFINE(HAVE_NETBSD_FORM_H,1,[Define to 1 if we appear to be using NetBSD form.h])
2485 ])dnl
2486 dnl ---------------------------------------------------------------------------
2487 dnl CF_NETBSD_MENU_H version: 2 updated: 2012/10/06 16:39:58
2488 dnl ----------------
2489 dnl Check for NetBSD's menu.h, which is incompatible with SVr4 and ncurses.
2490 dnl Some workarounds are needed in client programs to allow them to compile.
2491 AC_DEFUN([CF_NETBSD_MENU_H],[
2492 AC_CACHE_CHECK(for NetBSD menu.h,cf_cv_netbsd_menu_h,[
2493 AC_TRY_COMPILE([
2494 #include <${cf_cv_ncurses_header:-curses.h}>
2495 #include <menu.h>
2496 ],[
2497         MENU *menu;
2498         int y = menu->max_item_width;
2499 ],[cf_cv_netbsd_menu_h=yes
2500 ],[cf_cv_netbsd_menu_h=no])
2501 ])
2502
2503 test "$cf_cv_netbsd_menu_h" = yes && AC_DEFINE(HAVE_NETBSD_MENU_H,1,[Define to 1 if we appear to be using NetBSD menu.h])
2504 ])dnl
2505 dnl ---------------------------------------------------------------------------
2506 dnl CF_NO_LEAKS_OPTION version: 6 updated: 2015/04/12 15:39:00
2507 dnl ------------------
2508 dnl see CF_WITH_NO_LEAKS
2509 AC_DEFUN([CF_NO_LEAKS_OPTION],[
2510 AC_MSG_CHECKING(if you want to use $1 for testing)
2511 AC_ARG_WITH($1,
2512         [$2],
2513         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
2514          $4
2515 ])
2516         : ${with_cflags:=-g}
2517         : ${with_no_leaks:=yes}
2518          with_$1=yes],
2519         [with_$1=])
2520 AC_MSG_RESULT(${with_$1:-no})
2521
2522 case .$with_cflags in
2523 (.*-g*)
2524         case .$CFLAGS in
2525         (.*-g*)
2526                 ;;
2527         (*)
2528                 CF_ADD_CFLAGS([-g])
2529                 ;;
2530         esac
2531         ;;
2532 esac
2533 ])dnl
2534 dnl ---------------------------------------------------------------------------
2535 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
2536 dnl --------------
2537 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2538 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2539 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2540 dnl delayed evaluation of those symbols.
2541 AC_DEFUN([CF_PATH_SYNTAX],[
2542 if test "x$prefix" != xNONE; then
2543         cf_path_syntax="$prefix"
2544 else
2545         cf_path_syntax="$ac_default_prefix"
2546 fi
2547
2548 case ".[$]$1" in
2549 (.\[$]\(*\)*|.\'*\'*)
2550         ;;
2551 (..|./*|.\\*)
2552         ;;
2553 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
2554         ;;
2555 (.\[$]{*prefix}*|.\[$]{*dir}*)
2556         eval $1="[$]$1"
2557         case ".[$]$1" in
2558         (.NONE/*)
2559                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2560                 ;;
2561         esac
2562         ;;
2563 (.no|.NONE/*)
2564         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2565         ;;
2566 (*)
2567         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2568         ;;
2569 esac
2570 ])dnl
2571 dnl ---------------------------------------------------------------------------
2572 dnl CF_PDCURSES_X11 version: 13 updated: 2012/10/06 16:39:58
2573 dnl ---------------
2574 dnl Configure for PDCurses' X11 library
2575 AC_DEFUN([CF_PDCURSES_X11],[
2576 AC_REQUIRE([CF_X_ATHENA])
2577
2578 CF_ACVERSION_CHECK(2.52,
2579         [AC_CHECK_TOOLS(XCURSES_CONFIG, xcurses-config, none)],
2580         [AC_PATH_PROGS(XCURSES_CONFIG, xcurses-config, none)])
2581
2582 if test "$XCURSES_CONFIG" != none ; then
2583
2584 CPPFLAGS="$CPPFLAGS `$XCURSES_CONFIG --cflags`"
2585 CF_ADD_LIBS(`$XCURSES_CONFIG --libs`)
2586
2587 cf_cv_lib_XCurses=yes
2588
2589 else
2590
2591 LDFLAGS="$LDFLAGS $X_LIBS"
2592 CF_CHECK_CFLAGS($X_CFLAGS)
2593 AC_CHECK_LIB(X11,XOpenDisplay,
2594         [CF_ADD_LIBS(-lX11)],,
2595         [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])
2596 AC_CACHE_CHECK(for XCurses library,cf_cv_lib_XCurses,[
2597 CF_ADD_LIBS(-lXCurses)
2598 AC_TRY_LINK([
2599 #include <xcurses.h>
2600 char *XCursesProgramName = "test";
2601 ],[XCursesExit();],
2602 [cf_cv_lib_XCurses=yes],
2603 [cf_cv_lib_XCurses=no])
2604 ])
2605
2606 fi
2607
2608 if test $cf_cv_lib_XCurses = yes ; then
2609         AC_DEFINE(UNIX,1,[Define to 1 if using PDCurses on Unix])
2610         AC_DEFINE(XCURSES,1,[Define to 1 if using PDCurses on Unix])
2611         AC_CHECK_HEADER(xcurses.h, AC_DEFINE(HAVE_XCURSES,1,[Define to 1 if using PDCurses on Unix]))
2612 else
2613         AC_MSG_ERROR(Cannot link with XCurses)
2614 fi
2615 ])dnl
2616 dnl ---------------------------------------------------------------------------
2617 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
2618 dnl -------------
2619 dnl Check for the package-config program, unless disabled by command-line.
2620 AC_DEFUN([CF_PKG_CONFIG],
2621 [
2622 AC_MSG_CHECKING(if you want to use pkg-config)
2623 AC_ARG_WITH(pkg-config,
2624         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2625         [cf_pkg_config=$withval],
2626         [cf_pkg_config=yes])
2627 AC_MSG_RESULT($cf_pkg_config)
2628
2629 case $cf_pkg_config in
2630 (no)
2631         PKG_CONFIG=none
2632         ;;
2633 (yes)
2634         CF_ACVERSION_CHECK(2.52,
2635                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2636                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2637         ;;
2638 (*)
2639         PKG_CONFIG=$withval
2640         ;;
2641 esac
2642
2643 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2644 if test "$PKG_CONFIG" != none ; then
2645         CF_PATH_SYNTAX(PKG_CONFIG)
2646 elif test "x$cf_pkg_config" != xno ; then
2647         AC_MSG_WARN(pkg-config is not installed)
2648 fi
2649
2650 AC_SUBST(PKG_CONFIG)
2651 ])dnl
2652 dnl ---------------------------------------------------------------------------
2653 dnl CF_POSIX_C_SOURCE version: 9 updated: 2015/04/12 15:39:00
2654 dnl -----------------
2655 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2656 dnl
2657 dnl     POSIX.1-1990                            _POSIX_SOURCE
2658 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2659 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2660 dnl             Bindings Option
2661 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2662 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2663 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2664 dnl
2665 dnl Parameters:
2666 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2667 AC_DEFUN([CF_POSIX_C_SOURCE],
2668 [
2669 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2670
2671 cf_save_CFLAGS="$CFLAGS"
2672 cf_save_CPPFLAGS="$CPPFLAGS"
2673
2674 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2675 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2676
2677 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2678         CF_MSG_LOG(if the symbol is already defined go no further)
2679         AC_TRY_COMPILE([#include <sys/types.h>],[
2680 #ifndef _POSIX_C_SOURCE
2681 make an error
2682 #endif],
2683         [cf_cv_posix_c_source=no],
2684         [cf_want_posix_source=no
2685          case .$cf_POSIX_C_SOURCE in
2686          (.[[12]]??*)
2687                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2688                 ;;
2689          (.2)
2690                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2691                 cf_want_posix_source=yes
2692                 ;;
2693          (.*)
2694                 cf_want_posix_source=yes
2695                 ;;
2696          esac
2697          if test "$cf_want_posix_source" = yes ; then
2698                 AC_TRY_COMPILE([#include <sys/types.h>],[
2699 #ifdef _POSIX_SOURCE
2700 make an error
2701 #endif],[],
2702                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2703          fi
2704          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2705          CFLAGS="$cf_trim_CFLAGS"
2706          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
2707          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2708          AC_TRY_COMPILE([#include <sys/types.h>],[
2709 #ifndef _POSIX_C_SOURCE
2710 make an error
2711 #endif],,
2712          [cf_cv_posix_c_source=no])
2713          CFLAGS="$cf_save_CFLAGS"
2714          CPPFLAGS="$cf_save_CPPFLAGS"
2715         ])
2716 ])
2717
2718 if test "$cf_cv_posix_c_source" != no ; then
2719         CFLAGS="$cf_trim_CFLAGS"
2720         CPPFLAGS="$cf_trim_CPPFLAGS"
2721         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2722 fi
2723
2724 ])dnl
2725 dnl ---------------------------------------------------------------------------
2726 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
2727 dnl ------------
2728 dnl Append definitions and rules for the given programs to the subdirectory
2729 dnl Makefiles, and the recursion rule for the top-level Makefile.
2730 dnl
2731 dnl parameters
2732 dnl     $1 = script to run
2733 dnl     $2 = list of subdirectories
2734 dnl
2735 dnl variables
2736 dnl     $AWK
2737 AC_DEFUN([CF_PRG_RULES],
2738 [
2739 for cf_dir in $2
2740 do
2741         if test ! -d $srcdir/$cf_dir; then
2742                 continue
2743         elif test -f $srcdir/$cf_dir/programs; then
2744                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
2745         fi
2746 done
2747
2748 ])dnl
2749 dnl ---------------------------------------------------------------------------
2750 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
2751 dnl ----------
2752 dnl standard check for CC, plus followup sanity checks
2753 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
2754 AC_DEFUN([CF_PROG_CC],[
2755 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
2756 CF_GCC_VERSION
2757 CF_ACVERSION_CHECK(2.52,
2758         [AC_PROG_CC_STDC],
2759         [CF_ANSI_CC_REQD])
2760 CF_CC_ENV_FLAGS
2761 ])dnl
2762 dnl ---------------------------------------------------------------------------
2763 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
2764 dnl ---------------
2765 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
2766 dnl misc/tabset install won't work properly.  Usually this happens only when
2767 dnl using the fallback mkinstalldirs script
2768 AC_DEFUN([CF_PROG_INSTALL],
2769 [AC_PROG_INSTALL
2770 case $INSTALL in
2771 (/*)
2772         ;;
2773 (*)
2774         CF_DIRNAME(cf_dir,$INSTALL)
2775         test -z "$cf_dir" && cf_dir=.
2776         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
2777         ;;
2778 esac
2779 ])dnl
2780 dnl ---------------------------------------------------------------------------
2781 dnl CF_PROG_LINT version: 3 updated: 2016/05/22 15:25:54
2782 dnl ------------
2783 AC_DEFUN([CF_PROG_LINT],
2784 [
2785 AC_CHECK_PROGS(LINT, lint cppcheck splint)
2786 AC_SUBST(LINT_OPTS)
2787 ])dnl
2788 dnl ---------------------------------------------------------------------------
2789 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
2790 dnl ----------------
2791 dnl Remove all -U and -D options that refer to the given symbol from a list
2792 dnl of C compiler options.  This works around the problem that not all
2793 dnl compilers process -U and -D options from left-to-right, so a -U option
2794 dnl cannot be used to cancel the effect of a preceding -D option.
2795 dnl
2796 dnl $1 = target (which could be the same as the source variable)
2797 dnl $2 = source (including '$')
2798 dnl $3 = symbol to remove
2799 define([CF_REMOVE_DEFINE],
2800 [
2801 $1=`echo "$2" | \
2802         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
2803                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
2804 ])dnl
2805 dnl ---------------------------------------------------------------------------
2806 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
2807 dnl -------------
2808 AC_DEFUN([CF_RPATH_HACK],
2809 [
2810 AC_REQUIRE([CF_LD_RPATH_OPT])
2811 AC_MSG_CHECKING(for updated LDFLAGS)
2812 if test -n "$LD_RPATH_OPT" ; then
2813         AC_MSG_RESULT(maybe)
2814
2815         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
2816         cf_rpath_list="/usr/lib /lib"
2817         if test "$cf_ldd_prog" != no
2818         then
2819                 cf_rpath_oops=
2820
2821 AC_TRY_LINK([#include <stdio.h>],
2822                 [printf("Hello");],
2823                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
2824                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
2825
2826                 # If we passed the link-test, but get a "not found" on a given library,
2827                 # this could be due to inept reconfiguration of gcc to make it only
2828                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
2829                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
2830                 # /usr/local libraries.
2831                 if test -n "$cf_rpath_oops"
2832                 then
2833                         for cf_rpath_src in $cf_rpath_oops
2834                         do
2835                                 for cf_rpath_dir in \
2836                                         /usr/local \
2837                                         /usr/pkg \
2838                                         /opt/sfw
2839                                 do
2840                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
2841                                         then
2842                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
2843                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
2844                                                 break
2845                                         fi
2846                                 done
2847                         done
2848                 fi
2849         fi
2850
2851         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
2852
2853         CF_RPATH_HACK_2(LDFLAGS)
2854         CF_RPATH_HACK_2(LIBS)
2855
2856         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
2857 else
2858         AC_MSG_RESULT(no)
2859 fi
2860 AC_SUBST(EXTRA_LDFLAGS)
2861 ])dnl
2862 dnl ---------------------------------------------------------------------------
2863 dnl CF_RPATH_HACK_2 version: 7 updated: 2015/04/12 15:39:00
2864 dnl ---------------
2865 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
2866 dnl EXTRA_LDFLAGS for each -L option found.
2867 dnl
2868 dnl $cf_rpath_list contains a list of directories to ignore.
2869 dnl
2870 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
2871 dnl      but LIBS often has misplaced -L options.
2872 AC_DEFUN([CF_RPATH_HACK_2],
2873 [
2874 CF_VERBOSE(...checking $1 [$]$1)
2875
2876 cf_rpath_dst=
2877 for cf_rpath_src in [$]$1
2878 do
2879         case $cf_rpath_src in
2880         (-L*)
2881
2882                 # check if this refers to a directory which we will ignore
2883                 cf_rpath_skip=no
2884                 if test -n "$cf_rpath_list"
2885                 then
2886                         for cf_rpath_item in $cf_rpath_list
2887                         do
2888                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
2889                                 then
2890                                         cf_rpath_skip=yes
2891                                         break
2892                                 fi
2893                         done
2894                 fi
2895
2896                 if test "$cf_rpath_skip" = no
2897                 then
2898                         # transform the option
2899                         if test "$LD_RPATH_OPT" = "-R " ; then
2900                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
2901                         else
2902                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
2903                         fi
2904
2905                         # if we have not already added this, add it now
2906                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
2907                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
2908                         then
2909                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
2910                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
2911                         fi
2912                 fi
2913                 ;;
2914         esac
2915         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
2916 done
2917 $1=$cf_rpath_dst
2918
2919 CF_VERBOSE(...checked $1 [$]$1)
2920 AC_SUBST(EXTRA_LDFLAGS)
2921 ])dnl
2922 dnl ---------------------------------------------------------------------------
2923 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
2924 dnl -----------
2925 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
2926 dnl programs need this test).
2927 dnl
2928 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
2929 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
2930 dnl winsize declaration is left alone - we may revisit this if Apple choose to
2931 dnl break that part of the interface as well.
2932 AC_DEFUN([CF_SIGWINCH],
2933 [
2934 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
2935         AC_TRY_COMPILE([
2936 #include <sys/types.h>
2937 #include <sys/signal.h>
2938 ],[int x = SIGWINCH],
2939         [cf_cv_define_sigwinch=yes],
2940         [AC_TRY_COMPILE([
2941 #undef _XOPEN_SOURCE
2942 #undef _POSIX_SOURCE
2943 #undef _POSIX_C_SOURCE
2944 #include <sys/types.h>
2945 #include <sys/signal.h>
2946 ],[int x = SIGWINCH],
2947         [cf_cv_define_sigwinch=maybe],
2948         [cf_cv_define_sigwinch=no])
2949 ])
2950 ])
2951
2952 if test "$cf_cv_define_sigwinch" = maybe ; then
2953 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
2954 cf_cv_fixup_sigwinch=unknown
2955 cf_sigwinch=32
2956 while test $cf_sigwinch != 1
2957 do
2958         AC_TRY_COMPILE([
2959 #undef _XOPEN_SOURCE
2960 #undef _POSIX_SOURCE
2961 #undef _POSIX_C_SOURCE
2962 #include <sys/types.h>
2963 #include <sys/signal.h>
2964 ],[
2965 #if SIGWINCH != $cf_sigwinch
2966 make an error
2967 #endif
2968 int x = SIGWINCH],
2969         [cf_cv_fixup_sigwinch=$cf_sigwinch
2970          break])
2971
2972 cf_sigwinch=`expr $cf_sigwinch - 1`
2973 done
2974 ])
2975
2976         if test "$cf_cv_fixup_sigwinch" != unknown ; then
2977                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
2978         fi
2979 fi
2980 ])dnl
2981 dnl ---------------------------------------------------------------------------
2982 dnl CF_SIG_ATOMIC_T version: 3 updated: 2012/10/04 20:12:20
2983 dnl ---------------
2984 dnl signal handler, but there are some gcc depedencies in that recommendation.
2985 dnl Try anyway.
2986 AC_DEFUN([CF_SIG_ATOMIC_T],
2987 [
2988 AC_MSG_CHECKING(for signal global datatype)
2989 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
2990         for cf_type in \
2991                 "volatile sig_atomic_t" \
2992                 "sig_atomic_t" \
2993                 "int"
2994         do
2995         AC_TRY_COMPILE([
2996 #include <sys/types.h>
2997 #include <signal.h>
2998 #include <stdio.h>
2999
3000 extern $cf_type x;
3001 $cf_type x;
3002 static void handler(int sig)
3003 {
3004         x = 5;
3005 }],
3006                 [signal(SIGINT, handler);
3007                  x = 1],
3008                 [cf_cv_sig_atomic_t=$cf_type],
3009                 [cf_cv_sig_atomic_t=no])
3010                 test "$cf_cv_sig_atomic_t" != no && break
3011         done
3012         ])
3013 AC_MSG_RESULT($cf_cv_sig_atomic_t)
3014 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
3015 ])dnl
3016 dnl ---------------------------------------------------------------------------
3017 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
3018 dnl --------------
3019 dnl Construct a search-list for a nonstandard header/lib-file
3020 dnl     $1 = the variable to return as result
3021 dnl     $2 = the package name
3022 dnl     $3 = the subdirectory, e.g., bin, include or lib
3023 AC_DEFUN([CF_SUBDIR_PATH],
3024 [
3025 $1=
3026
3027 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
3028
3029 for cf_subdir_prefix in \
3030         /usr \
3031         /usr/local \
3032         /usr/pkg \
3033         /opt \
3034         /opt/local \
3035         [$]HOME
3036 do
3037         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
3038 done
3039 ])dnl
3040 dnl ---------------------------------------------------------------------------
3041 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
3042 dnl ------------------
3043 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
3044 dnl older SCO configurations.
3045 AC_DEFUN([CF_SYS_TIME_SELECT],
3046 [
3047 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
3048 AC_CACHE_VAL(cf_cv_sys_time_select,[
3049 AC_TRY_COMPILE([
3050 #include <sys/types.h>
3051 #ifdef HAVE_SYS_TIME_H
3052 #include <sys/time.h>
3053 #endif
3054 #ifdef HAVE_SYS_SELECT_H
3055 #include <sys/select.h>
3056 #endif
3057 ],[],[cf_cv_sys_time_select=yes],
3058          [cf_cv_sys_time_select=no])
3059          ])
3060 AC_MSG_RESULT($cf_cv_sys_time_select)
3061 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
3062 ])dnl
3063 dnl ---------------------------------------------------------------------------
3064 dnl CF_TERM_HEADER version: 4 updated: 2015/04/15 19:08:48
3065 dnl --------------
3066 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
3067 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
3068 dnl but some packagers change this, breaking various applications.
3069 AC_DEFUN([CF_TERM_HEADER],[
3070 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
3071 case ${cf_cv_ncurses_header} in
3072 (*/ncurses.h|*/ncursesw.h)
3073         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
3074         ;;
3075 (*)
3076         cf_term_header=term.h
3077         ;;
3078 esac
3079
3080 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
3081 do
3082 AC_TRY_COMPILE([#include <stdio.h>
3083 #include <${cf_cv_ncurses_header:-curses.h}>
3084 #include <$cf_test>
3085 ],[int x = auto_left_margin],[
3086         cf_cv_term_header="$cf_test"],[
3087         cf_cv_term_header=unknown
3088         ])
3089         test "$cf_cv_term_header" != unknown && break
3090 done
3091 ])
3092
3093 # Set definitions to allow ifdef'ing to accommodate subdirectories
3094
3095 case $cf_cv_term_header in
3096 (*term.h)
3097         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
3098         ;;
3099 esac
3100
3101 case $cf_cv_term_header in
3102 (ncurses/term.h)
3103         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
3104         ;;
3105 (ncursesw/term.h)
3106         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
3107         ;;
3108 esac
3109 ])dnl
3110 dnl ---------------------------------------------------------------------------
3111 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
3112 dnl ---------------
3113 dnl Define a top_builddir symbol, for applications that need an absolute path.
3114 AC_DEFUN([CF_TOP_BUILDDIR],
3115 [
3116 top_builddir=ifelse($1,,`pwd`,$1)
3117 AC_SUBST(top_builddir)
3118 ])dnl
3119 dnl ---------------------------------------------------------------------------
3120 dnl CF_TPUTS_PROTO version: 3 updated: 2015/04/17 21:26:14
3121 dnl --------------
3122 dnl Check for type of function-pointer passed to tputs.  Some old
3123 dnl implementations used functions that had different prototypes, making it
3124 dnl hard to compile portable programs using tputs.
3125 AC_DEFUN([CF_TPUTS_PROTO],[
3126 CF_CURSES_FUNCS(tputs)
3127 if test x$cf_cv_func_tputs = xyes
3128 then
3129         cf_done=no
3130         for cf_arg in int char
3131         do
3132                 for cf_ret in int void
3133                 do
3134                         if test $cf_ret = void
3135                         then
3136                                 cf_return="/* nothing */"
3137                         else
3138                                 cf_return="return value"
3139                         fi
3140                         AC_TRY_COMPILE([
3141 #include <${cf_cv_ncurses_header:-curses.h}>
3142 #include <$cf_cv_term_header>
3143
3144 static $cf_ret outc($cf_arg value) { $cf_return; }
3145 ],[
3146         tputs("hello", 0, outc);
3147         ${cf_cv_main_return:-return}(0);
3148 ],[
3149                 CF_VERBOSE([prototype $cf_ret func($cf_arg value)])
3150                 cat >>confdefs.h <<EOF
3151 #define TPUTS_ARG               $cf_arg
3152 #define TPUTS_PROTO(func,value) $cf_ret func(TPUTS_ARG value)
3153 #define TPUTS_RETURN(value)     $cf_return
3154 EOF
3155                 cf_done=yes
3156                 break
3157 ])
3158                 done
3159                 test $cf_done = yes && break
3160         done
3161 fi
3162 ])dnl
3163 dnl ---------------------------------------------------------------------------
3164 dnl CF_TRIM_X_LIBS version: 3 updated: 2015/04/12 15:39:00
3165 dnl --------------
3166 dnl Trim extra base X libraries added as a workaround for inconsistent library
3167 dnl dependencies returned by "new" pkg-config files.
3168 AC_DEFUN([CF_TRIM_X_LIBS],[
3169         for cf_trim_lib in Xmu Xt X11
3170         do
3171                 case "$LIBS" in
3172                 (*-l$cf_trim_lib\ *-l$cf_trim_lib*)
3173                         LIBS=`echo "$LIBS " | sed -e 's/  / /g' -e 's%-l'"$cf_trim_lib"' %%' -e 's/ $//'`
3174                         CF_VERBOSE(..trimmed $LIBS)
3175                         ;;
3176                 esac
3177         done
3178 ])
3179 dnl ---------------------------------------------------------------------------
3180 dnl CF_TRY_PKG_CONFIG version: 5 updated: 2013/07/06 21:27:06
3181 dnl -----------------
3182 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
3183 dnl available in that form.
3184 dnl
3185 dnl $1 = package name
3186 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
3187 dnl $3 = logic to use if pkg-config does not have the package
3188 AC_DEFUN([CF_TRY_PKG_CONFIG],[
3189 AC_REQUIRE([CF_PKG_CONFIG])
3190
3191 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists $1; then
3192         CF_VERBOSE(found package $1)
3193         cf_pkgconfig_incs="`$PKG_CONFIG --cflags $1 2>/dev/null`"
3194         cf_pkgconfig_libs="`$PKG_CONFIG --libs   $1 2>/dev/null`"
3195         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
3196         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
3197         CF_ADD_CFLAGS($cf_pkgconfig_incs)
3198         CF_ADD_LIBS($cf_pkgconfig_libs)
3199         ifelse([$2],,:,[$2])
3200 else
3201         cf_pkgconfig_incs=
3202         cf_pkgconfig_libs=
3203         ifelse([$3],,:,[$3])
3204 fi
3205 ])
3206 dnl ---------------------------------------------------------------------------
3207 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
3208 dnl -------------------
3209 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
3210 dnl can define it successfully.
3211 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
3212 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
3213         AC_TRY_COMPILE([
3214 #include <stdlib.h>
3215 #include <string.h>
3216 #include <sys/types.h>
3217 ],[
3218 #ifndef _XOPEN_SOURCE
3219 make an error
3220 #endif],
3221         [cf_cv_xopen_source=no],
3222         [cf_save="$CPPFLAGS"
3223          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3224          AC_TRY_COMPILE([
3225 #include <stdlib.h>
3226 #include <string.h>
3227 #include <sys/types.h>
3228 ],[
3229 #ifdef _XOPEN_SOURCE
3230 make an error
3231 #endif],
3232         [cf_cv_xopen_source=no],
3233         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
3234         CPPFLAGS="$cf_save"
3235         ])
3236 ])
3237
3238 if test "$cf_cv_xopen_source" != no ; then
3239         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
3240         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
3241         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
3242         CF_ADD_CFLAGS($cf_temp_xopen_source)
3243 fi
3244 ])
3245 dnl ---------------------------------------------------------------------------
3246 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
3247 dnl --------
3248 dnl Make an uppercase version of a variable
3249 dnl $1=uppercase($2)
3250 AC_DEFUN([CF_UPPER],
3251 [
3252 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
3253 ])dnl
3254 dnl ---------------------------------------------------------------------------
3255 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
3256 dnl -----------
3257 dnl Check for multibyte support, and if not found, utf8 compatibility library
3258 AC_DEFUN([CF_UTF8_LIB],
3259 [
3260 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
3261         cf_save_LIBS="$LIBS"
3262         AC_TRY_LINK([
3263 #include <stdlib.h>],[putwc(0,0);],
3264         [cf_cv_utf8_lib=yes],
3265         [CF_FIND_LINKAGE([
3266 #include <libutf8.h>],[putwc(0,0);],utf8,
3267                 [cf_cv_utf8_lib=add-on],
3268                 [cf_cv_utf8_lib=no])
3269 ])])
3270
3271 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
3272 # ncurses/ncursesw:
3273 if test "$cf_cv_utf8_lib" = "add-on" ; then
3274         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
3275         CF_ADD_INCDIR($cf_cv_header_path_utf8)
3276         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
3277         CF_ADD_LIBS($cf_cv_library_file_utf8)
3278 fi
3279 ])dnl
3280 dnl ---------------------------------------------------------------------------
3281 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
3282 dnl ----------
3283 dnl Use AC_VERBOSE w/o the warnings
3284 AC_DEFUN([CF_VERBOSE],
3285 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
3286 CF_MSG_LOG([$1])
3287 ])dnl
3288 dnl ---------------------------------------------------------------------------
3289 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
3290 dnl -------------
3291 dnl Check if type wide-character type $1 is declared, and if so, which header
3292 dnl file is needed.  The second parameter is used to set a shell variable when
3293 dnl the type is not found.  The first parameter sets a shell variable for the
3294 dnl opposite sense.
3295 AC_DEFUN([CF_WCHAR_TYPE],
3296 [
3297 # This is needed on Tru64 5.0 to declare $1
3298 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
3299 AC_TRY_COMPILE([
3300 #include <stdlib.h>
3301 #include <stdarg.h>
3302 #include <stdio.h>
3303 #ifdef HAVE_LIBUTF8_H
3304 #include <libutf8.h>
3305 #endif],
3306         [$1 state],
3307         [cf_cv_$1=no],
3308         [AC_TRY_COMPILE([
3309 #include <stdlib.h>
3310 #include <stdarg.h>
3311 #include <stdio.h>
3312 #include <wchar.h>
3313 #ifdef HAVE_LIBUTF8_H
3314 #include <libutf8.h>
3315 #endif],
3316         [$1 value],
3317         [cf_cv_$1=yes],
3318         [cf_cv_$1=unknown])])])
3319
3320 if test "$cf_cv_$1" = yes ; then
3321         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
3322         NEED_WCHAR_H=1
3323 fi
3324
3325 ifelse([$2],,,[
3326 # if we do not find $1 in either place, use substitution to provide a fallback.
3327 if test "$cf_cv_$1" = unknown ; then
3328         $2=1
3329 fi
3330 ])
3331 ifelse($3,,,[
3332 # if we find $1 in either place, use substitution to provide a fallback.
3333 if test "$cf_cv_$1" != unknown ; then
3334         $3=1
3335 fi
3336 ])
3337 ])dnl
3338 dnl ---------------------------------------------------------------------------
3339 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3340 dnl ------------------
3341 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3342 dnl libraries.
3343 AC_DEFUN([CF_WITH_CURSES_DIR],[
3344
3345 AC_MSG_CHECKING(for specific curses-directory)
3346 AC_ARG_WITH(curses-dir,
3347         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3348         [cf_cv_curses_dir=$withval],
3349         [cf_cv_curses_dir=no])
3350 AC_MSG_RESULT($cf_cv_curses_dir)
3351
3352 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3353 then
3354         CF_PATH_SYNTAX(withval)
3355         if test -d "$cf_cv_curses_dir"
3356         then
3357                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3358                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3359         fi
3360 fi
3361 ])dnl
3362 dnl ---------------------------------------------------------------------------
3363 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
3364 dnl ----------------
3365 dnl Configure-option for dbmalloc.  The optional parameter is used to override
3366 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
3367 AC_DEFUN([CF_WITH_DBMALLOC],[
3368 CF_NO_LEAKS_OPTION(dbmalloc,
3369         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
3370         [USE_DBMALLOC])
3371
3372 if test "$with_dbmalloc" = yes ; then
3373         AC_CHECK_HEADER(dbmalloc.h,
3374                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
3375 fi
3376 ])dnl
3377 dnl ---------------------------------------------------------------------------
3378 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
3379 dnl ---------------
3380 dnl Configure-option for dmalloc.  The optional parameter is used to override
3381 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
3382 AC_DEFUN([CF_WITH_DMALLOC],[
3383 CF_NO_LEAKS_OPTION(dmalloc,
3384         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
3385         [USE_DMALLOC])
3386
3387 if test "$with_dmalloc" = yes ; then
3388         AC_CHECK_HEADER(dmalloc.h,
3389                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
3390 fi
3391 ])dnl
3392 dnl ---------------------------------------------------------------------------
3393 dnl CF_WITH_NCURSES_ETC version: 5 updated: 2016/02/20 19:23:20
3394 dnl -------------------
3395 dnl Use this macro for programs which use any variant of "curses", e.g.,
3396 dnl "ncurses", and "PDCurses".  Programs that can use curses and some unrelated
3397 dnl library (such as slang) should use a "--with-screen=XXX" option.
3398 dnl
3399 dnl This does not use AC_DEFUN, because that would tell autoconf to run each
3400 dnl of the macros inside this one - before this macro.
3401 define([CF_WITH_NCURSES_ETC],[
3402 CF_WITH_CURSES_DIR
3403
3404 cf_cv_screen=curses
3405
3406 AC_MSG_CHECKING(for specified curses library type)
3407 AC_ARG_WITH(screen,
3408         [  --with-screen=XXX       use specified curses-libraries],
3409         [cf_cv_screen=$withval],[
3410
3411 AC_ARG_WITH(ncursesw,
3412         [  --with-ncursesw         use wide ncurses-libraries],
3413         [cf_cv_screen=ncursesw],[
3414
3415 AC_ARG_WITH(ncurses,
3416         [  --with-ncurses          use ncurses-libraries],
3417         [cf_cv_screen=ncurses],[
3418
3419 AC_ARG_WITH(pdcurses,
3420         [  --with-pdcurses         compile/link with pdcurses X11 library],
3421         [cf_cv_screen=pdcurses],[
3422
3423 AC_ARG_WITH(curses-colr,
3424         [  --with-curses-colr      compile/link with HPUX 10.x color-curses],
3425         [cf_cv_screen=curses_colr],[
3426
3427 AC_ARG_WITH(curses-5lib,
3428         [  --with-curses-5lib      compile/link with SunOS 5lib curses],
3429         [cf_cv_screen=curses_5lib])])])])])])
3430
3431 AC_MSG_RESULT($cf_cv_screen)
3432
3433 case $cf_cv_screen in
3434 (curses|curses_*)
3435         CF_CURSES_CONFIG
3436         ;;
3437 (ncursesw*)
3438         CF_UTF8_LIB
3439         CF_NCURSES_CONFIG($cf_cv_screen)
3440         ;;
3441 (ncurses*)
3442         CF_NCURSES_CONFIG($cf_cv_screen)
3443         ;;
3444 (pdcurses)
3445         CF_PDCURSES_X11
3446         ;;
3447 (*)
3448         AC_MSG_ERROR(unexpected screen-value: $cf_cv_screen)
3449         ;;
3450 esac
3451
3452 CF_NCURSES_PTHREADS($cf_cv_screen)
3453
3454 ])dnl
3455 dnl ---------------------------------------------------------------------------
3456 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
3457 dnl ----------------
3458 AC_DEFUN([CF_WITH_VALGRIND],[
3459 CF_NO_LEAKS_OPTION(valgrind,
3460         [  --with-valgrind         test: use valgrind],
3461         [USE_VALGRIND])
3462 ])dnl
3463 dnl ---------------------------------------------------------------------------
3464 dnl CF_XOPEN_CURSES version: 13 updated: 2015/12/12 20:59:52
3465 dnl ---------------
3466 dnl Test if we should define X/Open source for curses, needed on Digital Unix
3467 dnl 4.x, to see the extended functions, but breaks on IRIX 6.x.
3468 dnl
3469 dnl The getbegyx() check is needed for HPUX, which omits legacy macros such
3470 dnl as getbegy().  The latter is better design, but the former is standard.
3471 AC_DEFUN([CF_XOPEN_CURSES],
3472 [
3473 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
3474 AC_CACHE_CHECK(definition to turn on extended curses functions,cf_cv_need_xopen_extension,[
3475 cf_cv_need_xopen_extension=unknown
3476 AC_TRY_LINK([
3477 #include <stdlib.h>
3478 #include <${cf_cv_ncurses_header:-curses.h}>],[
3479 #if defined(NCURSES_VERSION_PATCH)
3480 #if (NCURSES_VERSION_PATCH < 20100501) && (NCURSES_VERSION_PATCH >= 20100403)
3481         make an error
3482 #endif
3483 #endif
3484 #ifdef NCURSES_VERSION
3485         cchar_t check;
3486         int check2 = curs_set((int)sizeof(check));
3487 #endif
3488         long x = winnstr(stdscr, "", 0);
3489         int x1, y1;
3490         getbegyx(stdscr, y1, x1)],
3491         [cf_cv_need_xopen_extension=none],
3492         [
3493         for cf_try_xopen_extension in _XOPEN_SOURCE_EXTENDED NCURSES_WIDECHAR
3494         do
3495                 AC_TRY_LINK([
3496 #define $cf_try_xopen_extension 1
3497 #include <stdlib.h>
3498 #include <${cf_cv_ncurses_header:-curses.h}>],[
3499 #ifdef NCURSES_VERSION
3500                 cchar_t check;
3501                 int check2 = curs_set((int)sizeof(check));
3502 #endif
3503                 long x = winnstr(stdscr, "", 0);
3504                 int x1, y1;
3505                 getbegyx(stdscr, y1, x1)],
3506                 [cf_cv_need_xopen_extension=$cf_try_xopen_extension; break])
3507         done
3508         ])
3509 ])
3510
3511 case $cf_cv_need_xopen_extension in
3512 (*_*)
3513         CPPFLAGS="$CPPFLAGS -D$cf_cv_need_xopen_extension"
3514         ;;
3515 esac
3516
3517 ])dnl
3518 dnl ---------------------------------------------------------------------------
3519 dnl CF_XOPEN_SOURCE version: 52 updated: 2016/08/27 12:21:42
3520 dnl ---------------
3521 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
3522 dnl or adapt to the vendor's definitions to get equivalent functionality,
3523 dnl without losing the common non-POSIX features.
3524 dnl
3525 dnl Parameters:
3526 dnl     $1 is the nominal value for _XOPEN_SOURCE
3527 dnl     $2 is the nominal value for _POSIX_C_SOURCE
3528 AC_DEFUN([CF_XOPEN_SOURCE],[
3529 AC_REQUIRE([AC_CANONICAL_HOST])
3530
3531 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
3532 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
3533 cf_xopen_source=
3534
3535 case $host_os in
3536 (aix[[4-7]]*)
3537         cf_xopen_source="-D_ALL_SOURCE"
3538         ;;
3539 (msys)
3540         cf_XOPEN_SOURCE=600
3541         ;;
3542 (darwin[[0-8]].*)
3543         cf_xopen_source="-D_APPLE_C_SOURCE"
3544         ;;
3545 (darwin*)
3546         cf_xopen_source="-D_DARWIN_C_SOURCE"
3547         cf_XOPEN_SOURCE=
3548         ;;
3549 (freebsd*|dragonfly*)
3550         # 5.x headers associate
3551         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
3552         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
3553         cf_POSIX_C_SOURCE=200112L
3554         cf_XOPEN_SOURCE=600
3555         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3556         ;;
3557 (hpux11*)
3558         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
3559         ;;
3560 (hpux*)
3561         cf_xopen_source="-D_HPUX_SOURCE"
3562         ;;
3563 (irix[[56]].*)
3564         cf_xopen_source="-D_SGI_SOURCE"
3565         cf_XOPEN_SOURCE=
3566         ;;
3567 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
3568         CF_GNU_SOURCE
3569         ;;
3570 (minix*)
3571         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
3572         ;;
3573 (mirbsd*)
3574         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
3575         cf_XOPEN_SOURCE=
3576         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3577         ;;
3578 (netbsd*)
3579         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
3580         ;;
3581 (openbsd[[4-9]]*)
3582         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
3583         cf_xopen_source="-D_BSD_SOURCE"
3584         cf_XOPEN_SOURCE=600
3585         ;;
3586 (openbsd*)
3587         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
3588         ;;
3589 (osf[[45]]*)
3590         cf_xopen_source="-D_OSF_SOURCE"
3591         ;;
3592 (nto-qnx*)
3593         cf_xopen_source="-D_QNX_SOURCE"
3594         ;;
3595 (sco*)
3596         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
3597         ;;
3598 (solaris2.*)
3599         cf_xopen_source="-D__EXTENSIONS__"
3600         cf_cv_xopen_source=broken
3601         ;;
3602 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
3603         cf_XOPEN_SOURCE=
3604         cf_POSIX_C_SOURCE=
3605         ;;
3606 (*)
3607         CF_TRY_XOPEN_SOURCE
3608         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3609         ;;
3610 esac
3611
3612 if test -n "$cf_xopen_source" ; then
3613         CF_ADD_CFLAGS($cf_xopen_source,true)
3614 fi
3615
3616 dnl In anything but the default case, we may have system-specific setting
3617 dnl which is still not guaranteed to provide all of the entrypoints that
3618 dnl _XOPEN_SOURCE would yield.
3619 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
3620         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
3621         AC_TRY_COMPILE([#include <stdlib.h>],[
3622 #ifndef _XOPEN_SOURCE
3623 make an error
3624 #endif],
3625         [cf_XOPEN_SOURCE_set=yes],
3626         [cf_XOPEN_SOURCE_set=no])
3627         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
3628         if test $cf_XOPEN_SOURCE_set = yes
3629         then
3630                 AC_TRY_COMPILE([#include <stdlib.h>],[
3631 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
3632 make an error
3633 #endif],
3634                 [cf_XOPEN_SOURCE_set_ok=yes],
3635                 [cf_XOPEN_SOURCE_set_ok=no])
3636                 if test $cf_XOPEN_SOURCE_set_ok = no
3637                 then
3638                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
3639                 fi
3640         else
3641                 CF_TRY_XOPEN_SOURCE
3642         fi
3643 fi
3644 ])
3645 dnl ---------------------------------------------------------------------------
3646 dnl CF_X_ATHENA version: 23 updated: 2015/04/12 15:39:00
3647 dnl -----------
3648 dnl Check for Xaw (Athena) libraries
3649 dnl
3650 dnl Sets $cf_x_athena according to the flavor of Xaw which is used.
3651 AC_DEFUN([CF_X_ATHENA],
3652 [
3653 cf_x_athena=${cf_x_athena:-Xaw}
3654
3655 AC_MSG_CHECKING(if you want to link with Xaw 3d library)
3656 withval=
3657 AC_ARG_WITH(Xaw3d,
3658         [  --with-Xaw3d            link with Xaw 3d library])
3659 if test "$withval" = yes ; then
3660         cf_x_athena=Xaw3d
3661         AC_MSG_RESULT(yes)
3662 else
3663         AC_MSG_RESULT(no)
3664 fi
3665
3666 AC_MSG_CHECKING(if you want to link with Xaw 3d xft library)
3667 withval=
3668 AC_ARG_WITH(Xaw3dxft,
3669         [  --with-Xaw3dxft         link with Xaw 3d xft library])
3670 if test "$withval" = yes ; then
3671         cf_x_athena=Xaw3dxft
3672         AC_MSG_RESULT(yes)
3673 else
3674         AC_MSG_RESULT(no)
3675 fi
3676
3677 AC_MSG_CHECKING(if you want to link with neXT Athena library)
3678 withval=
3679 AC_ARG_WITH(neXtaw,
3680         [  --with-neXtaw           link with neXT Athena library])
3681 if test "$withval" = yes ; then
3682         cf_x_athena=neXtaw
3683         AC_MSG_RESULT(yes)
3684 else
3685         AC_MSG_RESULT(no)
3686 fi
3687
3688 AC_MSG_CHECKING(if you want to link with Athena-Plus library)
3689 withval=
3690 AC_ARG_WITH(XawPlus,
3691         [  --with-XawPlus          link with Athena-Plus library])
3692 if test "$withval" = yes ; then
3693         cf_x_athena=XawPlus
3694         AC_MSG_RESULT(yes)
3695 else
3696         AC_MSG_RESULT(no)
3697 fi
3698
3699 cf_x_athena_lib=""
3700
3701 if test "$PKG_CONFIG" != none ; then
3702         cf_athena_list=
3703         test "$cf_x_athena" = Xaw && cf_athena_list="xaw8 xaw7 xaw6"
3704         for cf_athena_pkg in \
3705                 $cf_athena_list \
3706                 ${cf_x_athena} \
3707                 ${cf_x_athena}-devel \
3708                 lib${cf_x_athena} \
3709                 lib${cf_x_athena}-devel
3710         do
3711                 CF_TRY_PKG_CONFIG($cf_athena_pkg,[
3712                         cf_x_athena_lib="$cf_pkgconfig_libs"
3713                         CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
3714                         AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
3715
3716                         CF_TRIM_X_LIBS
3717
3718 AC_CACHE_CHECK(for usable $cf_x_athena/Xmu package,cf_cv_xaw_compat,[
3719 AC_TRY_LINK([
3720 #include <X11/Xmu/CharSet.h>
3721 ],[
3722 int check = XmuCompareISOLatin1("big", "small")
3723 ],[cf_cv_xaw_compat=yes],[cf_cv_xaw_compat=no])])
3724
3725                         if test "$cf_cv_xaw_compat" = no
3726                         then
3727                                 # workaround for broken ".pc" files...
3728                                 case "$cf_x_athena_lib" in
3729                                 (*-lXmu*)
3730                                         ;;
3731                                 (*)
3732                                         CF_VERBOSE(work around broken package)
3733                                         cf_save_xmu="$LIBS"
3734                                         cf_first_lib=`echo "$cf_save_xmu" | sed -e 's/^[ ][ ]*//' -e 's/ .*//'`
3735                                         CF_TRY_PKG_CONFIG(xmu,[
3736                                                         LIBS="$cf_save_xmu"
3737                                                         CF_ADD_LIB_AFTER($cf_first_lib,$cf_pkgconfig_libs)
3738                                                 ],[
3739                                                         CF_ADD_LIB_AFTER($cf_first_lib,-lXmu)
3740                                                 ])
3741                                         CF_TRIM_X_LIBS
3742                                         ;;
3743                                 esac
3744                         fi
3745
3746                         break])
3747         done
3748 fi
3749
3750 if test -z "$cf_x_athena_lib" ; then
3751         CF_X_EXT
3752         CF_X_TOOLKIT
3753         CF_X_ATHENA_CPPFLAGS($cf_x_athena)
3754         CF_X_ATHENA_LIBS($cf_x_athena)
3755 fi
3756 ])dnl
3757 dnl ---------------------------------------------------------------------------
3758 dnl CF_X_ATHENA_CPPFLAGS version: 5 updated: 2010/05/26 17:35:30
3759 dnl --------------------
3760 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
3761 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
3762 AC_DEFUN([CF_X_ATHENA_CPPFLAGS],
3763 [
3764 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
3765 cf_x_athena_inc=""
3766
3767 for cf_path in default \
3768         /usr/contrib/X11R6 \
3769         /usr/contrib/X11R5 \
3770         /usr/lib/X11R5 \
3771         /usr/local
3772 do
3773         if test -z "$cf_x_athena_inc" ; then
3774                 cf_save="$CPPFLAGS"
3775                 cf_test=X11/$cf_x_athena_root/SimpleMenu.h
3776                 if test $cf_path != default ; then
3777                         CPPFLAGS="$cf_save -I$cf_path/include"
3778                         AC_MSG_CHECKING(for $cf_test in $cf_path)
3779                 else
3780                         AC_MSG_CHECKING(for $cf_test)
3781                 fi
3782                 AC_TRY_COMPILE([
3783 #include <X11/Intrinsic.h>
3784 #include <$cf_test>],[],
3785                         [cf_result=yes],
3786                         [cf_result=no])
3787                 AC_MSG_RESULT($cf_result)
3788                 if test "$cf_result" = yes ; then
3789                         cf_x_athena_inc=$cf_path
3790                         break
3791                 else
3792                         CPPFLAGS="$cf_save"
3793                 fi
3794         fi
3795 done
3796
3797 if test -z "$cf_x_athena_inc" ; then
3798         AC_MSG_WARN(
3799 [Unable to successfully find Athena header files with test program])
3800 elif test "$cf_x_athena_inc" != default ; then
3801         CPPFLAGS="$CPPFLAGS -I$cf_x_athena_inc"
3802 fi
3803 ])
3804 dnl ---------------------------------------------------------------------------
3805 dnl CF_X_ATHENA_LIBS version: 12 updated: 2011/07/17 19:55:02
3806 dnl ----------------
3807 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
3808 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
3809 AC_DEFUN([CF_X_ATHENA_LIBS],
3810 [AC_REQUIRE([CF_X_TOOLKIT])
3811 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
3812 cf_x_athena_lib=""
3813
3814 for cf_path in default \
3815         /usr/contrib/X11R6 \
3816         /usr/contrib/X11R5 \
3817         /usr/lib/X11R5 \
3818         /usr/local
3819 do
3820         for cf_lib in \
3821                 ${cf_x_athena_root} \
3822                 ${cf_x_athena_root}7 \
3823                 ${cf_x_athena_root}6
3824         do
3825         for cf_libs in \
3826                 "-l$cf_lib -lXmu" \
3827                 "-l$cf_lib -lXpm -lXmu" \
3828                 "-l${cf_lib}_s -lXmu_s"
3829         do
3830                 if test -z "$cf_x_athena_lib" ; then
3831                         cf_save="$LIBS"
3832                         cf_test=XawSimpleMenuAddGlobalActions
3833                         if test $cf_path != default ; then
3834                                 CF_ADD_LIBS(-L$cf_path/lib $cf_libs)
3835                                 AC_MSG_CHECKING(for $cf_libs in $cf_path)
3836                         else
3837                                 CF_ADD_LIBS($cf_libs)
3838                                 AC_MSG_CHECKING(for $cf_test in $cf_libs)
3839                         fi
3840                         AC_TRY_LINK([
3841 #include <X11/Intrinsic.h>
3842 #include <X11/$cf_x_athena_root/SimpleMenu.h>
3843 ],[
3844 $cf_test((XtAppContext) 0)],
3845                                 [cf_result=yes],
3846                                 [cf_result=no])
3847                         AC_MSG_RESULT($cf_result)
3848                         if test "$cf_result" = yes ; then
3849                                 cf_x_athena_lib="$cf_libs"
3850                                 break
3851                         fi
3852                         LIBS="$cf_save"
3853                 fi
3854         done # cf_libs
3855                 test -n "$cf_x_athena_lib" && break
3856         done # cf_lib
3857 done
3858
3859 if test -z "$cf_x_athena_lib" ; then
3860         AC_MSG_ERROR(
3861 [Unable to successfully link Athena library (-l$cf_x_athena_root) with test program])
3862 fi
3863
3864 CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
3865 AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
3866 ])
3867 dnl ---------------------------------------------------------------------------
3868 dnl CF_X_EXT version: 3 updated: 2010/06/02 05:03:05
3869 dnl --------
3870 AC_DEFUN([CF_X_EXT],[
3871 CF_TRY_PKG_CONFIG(Xext,,[
3872         AC_CHECK_LIB(Xext,XextCreateExtension,
3873                 [CF_ADD_LIB(Xext)])])
3874 ])dnl
3875 dnl ---------------------------------------------------------------------------
3876 dnl CF_X_TOOLKIT version: 23 updated: 2015/04/12 15:39:00
3877 dnl ------------
3878 dnl Check for X Toolkit libraries
3879 AC_DEFUN([CF_X_TOOLKIT],
3880 [
3881 AC_REQUIRE([AC_PATH_XTRA])
3882 AC_REQUIRE([CF_CHECK_CACHE])
3883
3884 # OSX is schizoid about who owns /usr/X11 (old) versus /opt/X11 (new), and (and
3885 # in some cases has installed dummy files in the former, other cases replaced
3886 # it with a link to the new location).  This complicates the configure script.
3887 # Check for that pitfall, and recover using pkg-config
3888 #
3889 # If none of these are set, the configuration is almost certainly broken.
3890 if test -z "${X_CFLAGS}${X_PRE_LIBS}${X_LIBS}${X_EXTRA_LIBS}"
3891 then
3892         CF_TRY_PKG_CONFIG(x11,,[AC_MSG_WARN(unable to find X11 library)])
3893         CF_TRY_PKG_CONFIG(ice,,[AC_MSG_WARN(unable to find ICE library)])
3894         CF_TRY_PKG_CONFIG(sm,,[AC_MSG_WARN(unable to find SM library)])
3895         CF_TRY_PKG_CONFIG(xt,,[AC_MSG_WARN(unable to find Xt library)])
3896 fi
3897
3898 cf_have_X_LIBS=no
3899
3900 CF_TRY_PKG_CONFIG(xt,[
3901
3902         case "x$LIBS" in
3903         (*-lX11*)
3904                 ;;
3905         (*)
3906 # we have an "xt" package, but it may omit Xt's dependency on X11
3907 AC_CACHE_CHECK(for usable X dependency,cf_cv_xt_x11_compat,[
3908 AC_TRY_LINK([
3909 #include <X11/Xlib.h>
3910 ],[
3911         int rc1 = XDrawLine((Display*) 0, (Drawable) 0, (GC) 0, 0, 0, 0, 0);
3912         int rc2 = XClearWindow((Display*) 0, (Window) 0);
3913         int rc3 = XMoveWindow((Display*) 0, (Window) 0, 0, 0);
3914         int rc4 = XMoveResizeWindow((Display*)0, (Window)0, 0, 0, 0, 0);
3915 ],[cf_cv_xt_x11_compat=yes],[cf_cv_xt_x11_compat=no])])
3916                 if test "$cf_cv_xt_x11_compat" = no
3917                 then
3918                         CF_VERBOSE(work around broken X11 dependency)
3919                         # 2010/11/19 - good enough until a working Xt on Xcb is delivered.
3920                         CF_TRY_PKG_CONFIG(x11,,[CF_ADD_LIB_AFTER(-lXt,-lX11)])
3921                 fi
3922                 ;;
3923         esac
3924
3925 AC_CACHE_CHECK(for usable X Toolkit package,cf_cv_xt_ice_compat,[
3926 AC_TRY_LINK([
3927 #include <X11/Shell.h>
3928 ],[int num = IceConnectionNumber(0)
3929 ],[cf_cv_xt_ice_compat=yes],[cf_cv_xt_ice_compat=no])])
3930
3931         if test "$cf_cv_xt_ice_compat" = no
3932         then
3933                 # workaround for broken ".pc" files used for X Toolkit.
3934                 case "x$X_PRE_LIBS" in
3935                 (*-lICE*)
3936                         case "x$LIBS" in
3937                         (*-lICE*)
3938                                 ;;
3939                         (*)
3940                                 CF_VERBOSE(work around broken ICE dependency)
3941                                 CF_TRY_PKG_CONFIG(ice,
3942                                         [CF_TRY_PKG_CONFIG(sm)],
3943                                         [CF_ADD_LIB_AFTER(-lXt,$X_PRE_LIBS)])
3944                                 ;;
3945                         esac
3946                         ;;
3947                 esac
3948         fi
3949
3950         cf_have_X_LIBS=yes
3951 ],[
3952
3953         LDFLAGS="$X_LIBS $LDFLAGS"
3954         CF_CHECK_CFLAGS($X_CFLAGS)
3955
3956         AC_CHECK_FUNC(XOpenDisplay,,[
3957         AC_CHECK_LIB(X11,XOpenDisplay,
3958                 [CF_ADD_LIB(X11)],,
3959                 [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])])
3960
3961         AC_CHECK_FUNC(XtAppInitialize,,[
3962         AC_CHECK_LIB(Xt, XtAppInitialize,
3963                 [AC_DEFINE(HAVE_LIBXT,1,[Define to 1 if we can compile with the Xt library])
3964                  cf_have_X_LIBS=Xt
3965                  LIBS="-lXt $X_PRE_LIBS $LIBS $X_EXTRA_LIBS"],,
3966                 [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])])
3967 ])
3968
3969 if test $cf_have_X_LIBS = no ; then
3970         AC_MSG_WARN(
3971 [Unable to successfully link X Toolkit library (-lXt) with
3972 test program.  You will have to check and add the proper libraries by hand
3973 to makefile.])
3974 fi
3975 ])dnl
3976 dnl ---------------------------------------------------------------------------
3977 dnl CF__CURSES_HEAD version: 2 updated: 2010/10/23 15:54:49
3978 dnl ---------------
3979 dnl Define a reusable chunk which includes <curses.h> and <term.h> when they
3980 dnl are both available.
3981 define([CF__CURSES_HEAD],[
3982 #ifdef HAVE_XCURSES
3983 #include <xcurses.h>
3984 char * XCursesProgramName = "test";
3985 #else
3986 #include <${cf_cv_ncurses_header:-curses.h}>
3987 #if defined(NCURSES_VERSION) && defined(HAVE_NCURSESW_TERM_H)
3988 #include <ncursesw/term.h>
3989 #elif defined(NCURSES_VERSION) && defined(HAVE_NCURSES_TERM_H)
3990 #include <ncurses/term.h>
3991 #elif defined(HAVE_TERM_H)
3992 #include <term.h>
3993 #endif
3994 #endif
3995 ])