test/aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 2003-2013,2014 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl $Id: aclocal.m4,v 1.95 2014/04/12 22:32:11 tom Exp $
  30 dnl
  31 dnl Author: Thomas E. Dickey
  32 dnl
  33 dnl Macros used in NCURSES test programs auto-configuration script.
  34 dnl
  35 dnl These macros are maintained separately from NCURSES.  The copyright on
  36 dnl this file applies to the aggregation of macros and does not affect use of
  37 dnl these macros in other applications.
  38 dnl
  39 dnl See http://invisible-island.net/autoconf/ for additional information.
  40 dnl
  41 dnl ---------------------------------------------------------------------------
  42 dnl ---------------------------------------------------------------------------
  43 dnl CF_ACVERSION_CHECK version: 4 updated: 2013/03/04 19:52:56
  44 dnl ------------------
  45 dnl Conditionally generate script according to whether we're using a given autoconf.
  46 dnl
  47 dnl $1 = version to compare against
  48 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  49 dnl $3 = code to use if AC_ACVERSION is older than $1.
  50 define([CF_ACVERSION_CHECK],
  51 [
  52 ifdef([AC_ACVERSION], ,[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])dnl
  53 ifdef([m4_version_compare],
  54 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  55 [CF_ACVERSION_COMPARE(
  56 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  57 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  58 dnl ---------------------------------------------------------------------------
  59 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  60 dnl --------------------
  61 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  62 dnl                      MAJOR2, MINOR2, TERNARY2,
  63 dnl                      PRINTABLE2, not FOUND, FOUND)
  64 define([CF_ACVERSION_COMPARE],
  65 [ifelse(builtin([eval], [$2 < $5]), 1,
  66 [ifelse([$8], , ,[$8])],
  67 [ifelse([$9], , ,[$9])])])dnl
  68 dnl ---------------------------------------------------------------------------
  69 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
  70 dnl -------------
  71 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
  72 dnl The second parameter if given makes this macro verbose.
  73 dnl
  74 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
  75 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
  76 dnl confused by the quotes (which require backslashes to keep them usable).
  77 AC_DEFUN([CF_ADD_CFLAGS],
  78 [
  79 cf_fix_cppflags=no
  80 cf_new_cflags=
  81 cf_new_cppflags=
  82 cf_new_extra_cppflags=
  83
  84 for cf_add_cflags in $1
  85 do
  86 case $cf_fix_cppflags in
  87 no)
  88         case $cf_add_cflags in #(vi
  89         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
  90                 case $cf_add_cflags in
  91                 -D*)
  92                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
  93
  94                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
  95                                 && test -z "${cf_tst_cflags}" \
  96                                 && cf_fix_cppflags=yes
  97
  98                         if test $cf_fix_cppflags = yes ; then
  99                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 100                                 continue
 101                         elif test "${cf_tst_cflags}" = "\"'" ; then
 102                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 103                                 continue
 104                         fi
 105                         ;;
 106                 esac
 107                 case "$CPPFLAGS" in
 108                 *$cf_add_cflags) #(vi
 109                         ;;
 110                 *) #(vi
 111                         case $cf_add_cflags in #(vi
 112                         -D*)
 113                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 114                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 115                                 ;;
 116                         esac
 117                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 118                         ;;
 119                 esac
 120                 ;;
 121         *)
 122                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 123                 ;;
 124         esac
 125         ;;
 126 yes)
 127         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 128
 129         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 130
 131         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 132                 && test -z "${cf_tst_cflags}" \
 133                 && cf_fix_cppflags=no
 134         ;;
 135 esac
 136 done
 137
 138 if test -n "$cf_new_cflags" ; then
 139         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 140         CFLAGS="$CFLAGS $cf_new_cflags"
 141 fi
 142
 143 if test -n "$cf_new_cppflags" ; then
 144         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 145         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 146 fi
 147
 148 if test -n "$cf_new_extra_cppflags" ; then
 149         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 150         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 151 fi
 152
 153 AC_SUBST(EXTRA_CPPFLAGS)
 154
 155 ])dnl
 156 dnl ---------------------------------------------------------------------------
 157 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 158 dnl -------------
 159 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 160 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 161 dnl but old versions (and some misinstalled ones) need that.  To make things
 162 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 163 dnl the include-path).
 164 AC_DEFUN([CF_ADD_INCDIR],
 165 [
 166 if test -n "$1" ; then
 167   for cf_add_incdir in $1
 168   do
 169         while test $cf_add_incdir != /usr/include
 170         do
 171           if test -d $cf_add_incdir
 172           then
 173                 cf_have_incdir=no
 174                 if test -n "$CFLAGS$CPPFLAGS" ; then
 175                   # a loop is needed to ensure we can add subdirs of existing dirs
 176                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 177                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 178                           cf_have_incdir=yes; break
 179                         fi
 180                   done
 181                 fi
 182
 183                 if test "$cf_have_incdir" = no ; then
 184                   if test "$cf_add_incdir" = /usr/local/include ; then
 185                         if test "$GCC" = yes
 186                         then
 187                           cf_save_CPPFLAGS=$CPPFLAGS
 188                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 189                           AC_TRY_COMPILE([#include <stdio.h>],
 190                                   [printf("Hello")],
 191                                   [],
 192                                   [cf_have_incdir=yes])
 193                           CPPFLAGS=$cf_save_CPPFLAGS
 194                         fi
 195                   fi
 196                 fi
 197
 198                 if test "$cf_have_incdir" = no ; then
 199                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 200                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 201
 202                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 203                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 204                   cf_add_incdir="$cf_top_incdir"
 205                 else
 206                   break
 207                 fi
 208           fi
 209         done
 210   done
 211 fi
 212 ])dnl
 213 dnl ---------------------------------------------------------------------------
 214 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 215 dnl ----------
 216 dnl Add a library, used to enforce consistency.
 217 dnl
 218 dnl $1 = library to add, without the "-l"
 219 dnl $2 = variable to update (default $LIBS)
 220 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 221 dnl ---------------------------------------------------------------------------
 222 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 223 dnl -------------
 224 dnl     Adds to the library-path
 225 dnl
 226 dnl     Some machines have trouble with multiple -L options.
 227 dnl
 228 dnl $1 is the (list of) directory(s) to add
 229 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 230 dnl
 231 AC_DEFUN([CF_ADD_LIBDIR],
 232 [
 233 if test -n "$1" ; then
 234   for cf_add_libdir in $1
 235   do
 236     if test $cf_add_libdir = /usr/lib ; then
 237       :
 238     elif test -d $cf_add_libdir
 239     then
 240       cf_have_libdir=no
 241       if test -n "$LDFLAGS$LIBS" ; then
 242         # a loop is needed to ensure we can add subdirs of existing dirs
 243         for cf_test_libdir in $LDFLAGS $LIBS ; do
 244           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 245             cf_have_libdir=yes; break
 246           fi
 247         done
 248       fi
 249       if test "$cf_have_libdir" = no ; then
 250         CF_VERBOSE(adding $cf_add_libdir to library-path)
 251         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 252       fi
 253     fi
 254   done
 255 fi
 256 ])dnl
 257 dnl ---------------------------------------------------------------------------
 258 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 259 dnl -----------
 260 dnl Add one or more libraries, used to enforce consistency.
 261 dnl
 262 dnl $1 = libraries to add, with the "-l", etc.
 263 dnl $2 = variable to update (default $LIBS)
 264 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 265 dnl ---------------------------------------------------------------------------
 266 dnl CF_ADD_LIB_AFTER version: 3 updated: 2013/07/09 21:27:22
 267 dnl ----------------
 268 dnl Add a given library after another, e.g., following the one it satisfies a
 269 dnl dependency for.
 270 dnl
 271 dnl $1 = the first library
 272 dnl $2 = its dependency
 273 AC_DEFUN([CF_ADD_LIB_AFTER],[
 274 CF_VERBOSE(...before $LIBS)
 275 LIBS=`echo "$LIBS" | sed -e "s/[[       ]][[    ]]*/ /g" -e "s%$1 %$1 $2 %" -e 's%  % %g'`
 276 CF_VERBOSE(...after  $LIBS)
 277 ])dnl
 278 dnl ---------------------------------------------------------------------------
 279 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 280 dnl ------------------
 281 dnl Append to a search-list for a nonstandard header/lib-file
 282 dnl     $1 = the variable to return as result
 283 dnl     $2 = the package name
 284 dnl     $3 = the subdirectory, e.g., bin, include or lib
 285 dnl $4 = the directory under which we will test for subdirectories
 286 dnl $5 = a directory that we do not want $4 to match
 287 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 288 [
 289 test "x$4" != "x$5" && \
 290 test -d "$4" && \
 291 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 292         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 293         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 294         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 295         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 296         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 297         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 298 }
 299 ])dnl
 300 dnl ---------------------------------------------------------------------------
 301 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 302 dnl --------------
 303 dnl Allow user to disable a normally-on option.
 304 AC_DEFUN([CF_ARG_DISABLE],
 305 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 306 dnl ---------------------------------------------------------------------------
 307 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 308 dnl -------------
 309 dnl Allow user to enable a normally-off option.
 310 AC_DEFUN([CF_ARG_ENABLE],
 311 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 312 dnl ---------------------------------------------------------------------------
 313 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 314 dnl -------------
 315 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 316 dnl values.
 317 dnl
 318 dnl Parameters:
 319 dnl $1 = option name
 320 dnl $2 = help-string
 321 dnl $3 = action to perform if option is not default
 322 dnl $4 = action if perform if option is default
 323 dnl $5 = default option value (either 'yes' or 'no')
 324 AC_DEFUN([CF_ARG_OPTION],
 325 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 326   if test "$enableval" != "$5" ; then
 327 ifelse([$3],,[    :]dnl
 328 ,[    $3]) ifelse([$4],,,[
 329   else
 330     $4])
 331   fi],[enableval=$5 ifelse([$4],,,[
 332   $4
 333 ])dnl
 334   ])])dnl
 335 dnl ---------------------------------------------------------------------------
 336 dnl CF_CC_ENV_FLAGS version: 1 updated: 2012/10/03 05:25:49
 337 dnl ---------------
 338 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 339 dnl into CC.  This will not help with broken scripts that wrap the compiler with
 340 dnl options, but eliminates a more common category of user confusion.
 341 AC_DEFUN([CF_CC_ENV_FLAGS],
 342 [
 343 # This should have been defined by AC_PROG_CC
 344 : ${CC:=cc}
 345
 346 AC_MSG_CHECKING(\$CC variable)
 347 case "$CC" in #(vi
 348 *[[\ \  ]]-[[IUD]]*)
 349         AC_MSG_RESULT(broken)
 350         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 351         # humor him...
 352         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 353         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 354         CF_ADD_CFLAGS($cf_flags)
 355         ;;
 356 *)
 357         AC_MSG_RESULT(ok)
 358         ;;
 359 esac
 360 ])dnl
 361 dnl ---------------------------------------------------------------------------
 362 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 363 dnl --------------
 364 dnl Check if we're accidentally using a cache from a different machine.
 365 dnl Derive the system name, as a check for reusing the autoconf cache.
 366 dnl
 367 dnl If we've packaged config.guess and config.sub, run that (since it does a
 368 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 369 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 370 dnl which is useful in cross-compiles.
 371 dnl
 372 dnl Note: we would use $ac_config_sub, but that is one of the places where
 373 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 374 AC_DEFUN([CF_CHECK_CACHE],
 375 [
 376 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 377         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 378         system_name="$host_os"
 379 else
 380         system_name="`(uname -s -r) 2>/dev/null`"
 381         if test -z "$system_name" ; then
 382                 system_name="`(hostname) 2>/dev/null`"
 383         fi
 384 fi
 385 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 386 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 387
 388 test -z "$system_name" && system_name="$cf_cv_system_name"
 389 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 390
 391 if test ".$system_name" != ".$cf_cv_system_name" ; then
 392         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 393         AC_MSG_ERROR("Please remove config.cache and try again.")
 394 fi
 395 ])dnl
 396 dnl ---------------------------------------------------------------------------
 397 dnl CF_CHECK_CFLAGS version: 2 updated: 2001/12/30 19:09:58
 398 dnl ---------------
 399 dnl Conditionally add to $CFLAGS and $CPPFLAGS values which are derived from
 400 dnl a build-configuration such as imake.  These have the pitfall that they
 401 dnl often contain compiler-specific options which we cannot use, mixed with
 402 dnl preprocessor options that we usually can.
 403 AC_DEFUN([CF_CHECK_CFLAGS],
 404 [
 405 CF_VERBOSE(checking additions to CFLAGS)
 406 cf_check_cflags="$CFLAGS"
 407 cf_check_cppflags="$CPPFLAGS"
 408 CF_ADD_CFLAGS($1,yes)
 409 if test "$cf_check_cflags" != "$CFLAGS" ; then
 410 AC_TRY_LINK([#include <stdio.h>],[printf("Hello world");],,
 411         [CF_VERBOSE(test-compile failed.  Undoing change to \$CFLAGS)
 412          if test "$cf_check_cppflags" != "$CPPFLAGS" ; then
 413                  CF_VERBOSE(but keeping change to \$CPPFLAGS)
 414          fi
 415          CFLAGS="$cf_check_flags"])
 416 fi
 417 ])dnl
 418 dnl ---------------------------------------------------------------------------
 419 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
 420 dnl -----------------
 421 dnl Check if the given compiler is really clang.  clang's C driver defines
 422 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 423 dnl not ignore some gcc options.
 424 dnl
 425 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 426 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 427 dnl the wrappers for gcc and g++ warnings.
 428 dnl
 429 dnl $1 = GCC (default) or GXX
 430 dnl $2 = CLANG_COMPILER (default)
 431 dnl $3 = CFLAGS (default) or CXXFLAGS
 432 AC_DEFUN([CF_CLANG_COMPILER],[
 433 ifelse([$2],,CLANG_COMPILER,[$2])=no
 434
 435 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 436         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 437         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 438         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
 439         AC_TRY_COMPILE([],[
 440 #ifdef __clang__
 441 #else
 442 make an error
 443 #endif
 444 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 445 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
 446 ],[])
 447         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 448         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 449 fi
 450 ])
 451 dnl ---------------------------------------------------------------------------
 452 dnl CF_CURSES_ACS_MAP version: 7 updated: 2012/10/06 16:39:58
 453 dnl -----------------
 454 dnl Check for likely values of acs_map[]:
 455 AC_DEFUN([CF_CURSES_ACS_MAP],
 456 [
 457 AC_REQUIRE([CF_NCURSES_WRAP_PREFIX])dnl
 458 AC_CACHE_CHECK(for alternate character set array, cf_cv_curses_acs_map,[
 459 cf_cv_curses_acs_map=unknown
 460 for name in acs_map _acs_map __acs_map ${NCURSES_WRAP_PREFIX}acs_map
 461 do
 462 AC_TRY_LINK([
 463 #include <${cf_cv_ncurses_header:-curses.h}>
 464 ],[
 465 $name['k'] = ACS_PLUS
 466 ],[cf_cv_curses_acs_map=$name; break])
 467 done
 468 ])
 469
 470 test "$cf_cv_curses_acs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_ACS_ARRAY,$cf_cv_curses_acs_map,[Define as needed to override ncurses prefix _nc_])
 471 ])
 472 dnl ---------------------------------------------------------------------------
 473 dnl CF_CURSES_CHECK_DATA version: 4 updated: 2011/01/15 16:39:24
 474 dnl --------------------
 475 dnl Check if curses.h defines the given data/variable.
 476 dnl Use this after CF_NCURSES_CONFIG or CF_CURSES_CONFIG.
 477 AC_DEFUN([CF_CURSES_CHECK_DATA],
 478 [
 479 AC_MSG_CHECKING(for data $1 declaration in ${cf_cv_ncurses_header:-curses.h})
 480
 481 AC_TRY_COMPILE(CF__CURSES_HEAD,[
 482 void *foo = &($1)
 483 ],cf_result=yes,cf_result=no)
 484 AC_MSG_RESULT($cf_result)
 485
 486 if test $cf_result = yes ; then
 487         CF_UPPER(cf_result,have_curses_data_$1)
 488         AC_DEFINE_UNQUOTED($cf_result)
 489 else
 490         AC_MSG_CHECKING(for data $1 in library)
 491         # BSD linkers insist on making weak linkage, but resolve at runtime.
 492         AC_TRY_RUN(CF__CURSES_HEAD
 493 [
 494 extern char $1;
 495 int main(void)
 496 {
 497         void *foo = &($1);
 498         ${cf_cv_main_return:-return}(foo == 0);
 499 }],[cf_result=yes],[cf_result=no],[
 500         # cross-compiling
 501         AC_TRY_LINK(CF__CURSES_HEAD
 502 [extern char $1;],[
 503         do {
 504                 void *foo = &($1);
 505                 ${cf_cv_main_return:-return}(foo == 0);
 506         } while (0)
 507 ],[cf_result=yes],[cf_result=no])
 508 ])
 509         AC_MSG_RESULT($cf_result)
 510         if test $cf_result = yes ; then
 511                 CF_UPPER(cf_result,decl_curses_data_$1)
 512                 AC_DEFINE_UNQUOTED($cf_result)
 513         fi
 514 fi
 515 ])dnl
 516 dnl ---------------------------------------------------------------------------
 517 dnl CF_CURSES_CHECK_TYPE version: 4 updated: 2012/10/06 16:39:58
 518 dnl --------------------
 519 dnl Check if curses.h defines the given type
 520 AC_DEFUN([CF_CURSES_CHECK_TYPE],
 521 [
 522 AC_MSG_CHECKING(for type $1 in ${cf_cv_ncurses_header:-curses.h})
 523 AC_TRY_COMPILE([
 524 #ifndef _XOPEN_SOURCE_EXTENDED
 525 #define _XOPEN_SOURCE_EXTENDED
 526 #endif
 527 #include <${cf_cv_ncurses_header:-curses.h}>],[
 528 $1 foo
 529 ],cf_result=yes,cf_result=no)
 530 AC_MSG_RESULT($cf_result)
 531 if test $cf_result = yes ; then
 532         CF_UPPER(cf_result,have_type_$1)
 533         AC_DEFINE_UNQUOTED($cf_result,1,[Define to 1 if we have type $1])
 534 else
 535         AC_DEFINE_UNQUOTED($1,$2,[Define to appropriate type if $1 is not declared])
 536 fi
 537 ])dnl
 538 dnl ---------------------------------------------------------------------------
 539 dnl CF_CURSES_CONFIG version: 2 updated: 2006/10/29 11:06:27
 540 dnl ----------------
 541 dnl Tie together the configure-script macros for curses.  It may be ncurses,
 542 dnl but unless asked, we do not make a special search for ncurses.  However,
 543 dnl still check for the ncurses version number, for use in other macros.
 544 AC_DEFUN([CF_CURSES_CONFIG],
 545 [
 546 CF_CURSES_CPPFLAGS
 547 CF_NCURSES_VERSION
 548 CF_CURSES_LIBS
 549 ])dnl
 550 dnl ---------------------------------------------------------------------------
 551 dnl CF_CURSES_CPPFLAGS version: 11 updated: 2011/04/09 14:51:08
 552 dnl ------------------
 553 dnl Look for the curses headers.
 554 AC_DEFUN([CF_CURSES_CPPFLAGS],[
 555
 556 AC_CACHE_CHECK(for extra include directories,cf_cv_curses_incdir,[
 557 cf_cv_curses_incdir=no
 558 case $host_os in #(vi
 559 hpux10.*) #(vi
 560         if test "x$cf_cv_screen" = "xcurses_colr"
 561         then
 562                 test -d /usr/include/curses_colr && \
 563                 cf_cv_curses_incdir="-I/usr/include/curses_colr"
 564         fi
 565         ;;
 566 sunos3*|sunos4*)
 567         if test "x$cf_cv_screen" = "xcurses_5lib"
 568         then
 569                 test -d /usr/5lib && \
 570                 test -d /usr/5include && \
 571                 cf_cv_curses_incdir="-I/usr/5include"
 572         fi
 573         ;;
 574 esac
 575 ])
 576 test "$cf_cv_curses_incdir" != no && CPPFLAGS="$CPPFLAGS $cf_cv_curses_incdir"
 577
 578 CF_CURSES_HEADER
 579 CF_TERM_HEADER
 580 ])dnl
 581 dnl ---------------------------------------------------------------------------
 582 dnl CF_CURSES_FUNCS version: 17 updated: 2011/05/14 16:07:29
 583 dnl ---------------
 584 dnl Curses-functions are a little complicated, since a lot of them are macros.
 585 AC_DEFUN([CF_CURSES_FUNCS],
 586 [
 587 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 588 AC_REQUIRE([CF_XOPEN_CURSES])
 589 AC_REQUIRE([CF_CURSES_TERM_H])
 590 AC_REQUIRE([CF_CURSES_UNCTRL_H])
 591 for cf_func in $1
 592 do
 593         CF_UPPER(cf_tr_func,$cf_func)
 594         AC_MSG_CHECKING(for ${cf_func})
 595         CF_MSG_LOG(${cf_func})
 596         AC_CACHE_VAL(cf_cv_func_$cf_func,[
 597                 eval cf_result='$ac_cv_func_'$cf_func
 598                 if test ".$cf_result" != ".no"; then
 599                         AC_TRY_LINK(CF__CURSES_HEAD,
 600                         [
 601 #ifndef ${cf_func}
 602 long foo = (long)(&${cf_func});
 603 if (foo + 1234 > 5678)
 604         ${cf_cv_main_return:-return}(foo);
 605 #endif
 606                         ],
 607                         [cf_result=yes],
 608                         [cf_result=no])
 609                 fi
 610                 eval 'cf_cv_func_'$cf_func'=$cf_result'
 611         ])
 612         # use the computed/retrieved cache-value:
 613         eval 'cf_result=$cf_cv_func_'$cf_func
 614         AC_MSG_RESULT($cf_result)
 615         if test $cf_result != no; then
 616                 AC_DEFINE_UNQUOTED(HAVE_${cf_tr_func})
 617         fi
 618 done
 619 ])dnl
 620 dnl ---------------------------------------------------------------------------
 621 dnl CF_CURSES_HEADER version: 3 updated: 2011/05/01 19:47:45
 622 dnl ----------------
 623 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
 624 dnl variations of ncurses' installs.
 625 dnl
 626 dnl $1 = ncurses when looking for ncurses, or is empty
 627 AC_DEFUN([CF_CURSES_HEADER],[
 628 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
 629 cf_cv_ncurses_header=none
 630 for cf_header in ifelse($1,,,[ \
 631     $1/ncurses.h \
 632         $1/curses.h]) \
 633         ncurses.h \
 634         curses.h ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
 635 do
 636 AC_TRY_COMPILE([#include <${cf_header}>],
 637         [initscr(); tgoto("?", 0,0)],
 638         [cf_cv_ncurses_header=$cf_header; break],[])
 639 done
 640 ])
 641
 642 if test "$cf_cv_ncurses_header" = none ; then
 643         AC_MSG_ERROR(No curses header-files found)
 644 fi
 645
 646 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
 647 AC_CHECK_HEADERS($cf_cv_ncurses_header)
 648 ])dnl
 649 dnl ---------------------------------------------------------------------------
 650 dnl CF_CURSES_LIBS version: 37 updated: 2013/02/09 17:33:50
 651 dnl --------------
 652 dnl Look for the curses libraries.  Older curses implementations may require
 653 dnl termcap/termlib to be linked as well.  Call CF_CURSES_CPPFLAGS first.
 654 AC_DEFUN([CF_CURSES_LIBS],[
 655
 656 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 657 AC_MSG_CHECKING(if we have identified curses libraries)
 658 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 659     [initscr(); tgoto("?", 0,0)],
 660     cf_result=yes,
 661     cf_result=no)
 662 AC_MSG_RESULT($cf_result)
 663
 664 if test "$cf_result" = no ; then
 665 case $host_os in #(vi
 666 freebsd*) #(vi
 667     AC_CHECK_LIB(mytinfo,tgoto,[CF_ADD_LIBS(-lmytinfo)])
 668     ;;
 669 hpux10.*) #(vi
 670         # Looking at HPUX 10.20, the Hcurses library is the oldest (1997), cur_colr
 671         # next (1998), and xcurses "newer" (2000).  There is no header file for
 672         # Hcurses; the subdirectory curses_colr has the headers (curses.h and
 673         # term.h) for cur_colr
 674         if test "x$cf_cv_screen" = "xcurses_colr"
 675         then
 676                 AC_CHECK_LIB(cur_colr,initscr,[
 677                         CF_ADD_LIBS(-lcur_colr)
 678                         ac_cv_func_initscr=yes
 679                         ],[
 680                 AC_CHECK_LIB(Hcurses,initscr,[
 681                         # HP's header uses __HP_CURSES, but user claims _HP_CURSES.
 682                         CF_ADD_LIBS(-lHcurses)
 683                         CPPFLAGS="$CPPFLAGS -D__HP_CURSES -D_HP_CURSES"
 684                         ac_cv_func_initscr=yes
 685                         ])])
 686         fi
 687         ;;
 688 linux*)
 689         case `arch 2>/dev/null` in
 690         x86_64)
 691                 if test -d /lib64
 692                 then
 693                         CF_ADD_LIBDIR(/lib64)
 694                 else
 695                         CF_ADD_LIBDIR(/lib)
 696                 fi
 697                 ;;
 698         *)
 699                 CF_ADD_LIBDIR(/lib)
 700                 ;;
 701         esac
 702         ;;
 703 sunos3*|sunos4*)
 704         if test "x$cf_cv_screen" = "xcurses_5lib"
 705         then
 706                 if test -d /usr/5lib ; then
 707                         CF_ADD_LIBDIR(/usr/5lib)
 708                         CF_ADD_LIBS(-lcurses -ltermcap)
 709                 fi
 710     fi
 711     ac_cv_func_initscr=yes
 712     ;;
 713 esac
 714
 715 if test ".$ac_cv_func_initscr" != .yes ; then
 716         cf_save_LIBS="$LIBS"
 717
 718         if test ".${cf_cv_ncurses_version:-no}" != .no
 719         then
 720                 cf_check_list="ncurses curses cursesX"
 721         else
 722                 cf_check_list="cursesX curses ncurses"
 723         fi
 724
 725         # Check for library containing tgoto.  Do this before curses library
 726         # because it may be needed to link the test-case for initscr.
 727         if test "x$cf_term_lib" = x
 728         then
 729                 AC_CHECK_FUNC(tgoto,[cf_term_lib=predefined],[
 730                         for cf_term_lib in $cf_check_list otermcap termcap tinfo termlib unknown
 731                         do
 732                                 AC_CHECK_LIB($cf_term_lib,tgoto,[break])
 733                         done
 734                 ])
 735         fi
 736
 737         # Check for library containing initscr
 738         test "$cf_term_lib" != predefined && test "$cf_term_lib" != unknown && LIBS="-l$cf_term_lib $cf_save_LIBS"
 739         if test "x$cf_curs_lib" = x
 740         then
 741                 for cf_curs_lib in $cf_check_list xcurses jcurses pdcurses unknown
 742                 do
 743                         AC_CHECK_LIB($cf_curs_lib,initscr,[break])
 744                 done
 745         fi
 746         test $cf_curs_lib = unknown && AC_MSG_ERROR(no curses library found)
 747
 748         LIBS="-l$cf_curs_lib $cf_save_LIBS"
 749         if test "$cf_term_lib" = unknown ; then
 750                 AC_MSG_CHECKING(if we can link with $cf_curs_lib library)
 751                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 752                         [initscr()],
 753                         [cf_result=yes],
 754                         [cf_result=no])
 755                 AC_MSG_RESULT($cf_result)
 756                 test $cf_result = no && AC_MSG_ERROR(Cannot link curses library)
 757         elif test "$cf_curs_lib" = "$cf_term_lib" ; then
 758                 :
 759         elif test "$cf_term_lib" != predefined ; then
 760                 AC_MSG_CHECKING(if we need both $cf_curs_lib and $cf_term_lib libraries)
 761                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 762                         [initscr(); tgoto((char *)0, 0, 0);],
 763                         [cf_result=no],
 764                         [
 765                         LIBS="-l$cf_curs_lib -l$cf_term_lib $cf_save_LIBS"
 766                         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 767                                 [initscr()],
 768                                 [cf_result=yes],
 769                                 [cf_result=error])
 770                         ])
 771                 AC_MSG_RESULT($cf_result)
 772         fi
 773 fi
 774 fi
 775
 776 ])dnl
 777 dnl ---------------------------------------------------------------------------
 778 dnl CF_CURSES_TERM_H version: 10 updated: 2012/10/06 08:57:51
 779 dnl ----------------
 780 dnl SVr4 curses should have term.h as well (where it puts the definitions of
 781 dnl the low-level interface).  This may not be true in old/broken implementations,
 782 dnl as well as in misconfigured systems (e.g., gcc configured for Solaris 2.4
 783 dnl running with Solaris 2.5.1).
 784 AC_DEFUN([CF_CURSES_TERM_H],
 785 [
 786 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 787
 788 AC_CACHE_CHECK(for term.h, cf_cv_term_header,[
 789
 790 # If we found <ncurses/curses.h>, look for <ncurses/term.h>, but always look
 791 # for <term.h> if we do not find the variant.
 792
 793 cf_header_list="term.h ncurses/term.h ncursesw/term.h"
 794
 795 case ${cf_cv_ncurses_header:-curses.h} in #(vi
 796 */*)
 797         cf_header_item=`echo ${cf_cv_ncurses_header:-curses.h} | sed -e 's%\..*%%' -e 's%/.*%/%'`term.h
 798         cf_header_list="$cf_header_item $cf_header_list"
 799         ;;
 800 esac
 801
 802 for cf_header in $cf_header_list
 803 do
 804         AC_TRY_COMPILE([
 805 #include <${cf_cv_ncurses_header:-curses.h}>
 806 #include <${cf_header}>],
 807         [WINDOW *x],
 808         [cf_cv_term_header=$cf_header
 809          break],
 810         [cf_cv_term_header=no])
 811 done
 812
 813 case $cf_cv_term_header in #(vi
 814 no)
 815         # If curses is ncurses, some packagers still mess it up by trying to make
 816         # us use GNU termcap.  This handles the most common case.
 817         for cf_header in ncurses/term.h ncursesw/term.h
 818         do
 819                 AC_TRY_COMPILE([
 820 #include <${cf_cv_ncurses_header:-curses.h}>
 821 #ifdef NCURSES_VERSION
 822 #include <${cf_header}>
 823 #else
 824 make an error
 825 #endif],
 826                         [WINDOW *x],
 827                         [cf_cv_term_header=$cf_header
 828                          break],
 829                         [cf_cv_term_header=no])
 830         done
 831         ;;
 832 esac
 833 ])
 834
 835 case $cf_cv_term_header in #(vi
 836 term.h) #(vi
 837         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
 838         ;;
 839 ncurses/term.h) #(vi
 840         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
 841         ;;
 842 ncursesw/term.h)
 843         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
 844         ;;
 845 esac
 846 ])dnl
 847 dnl ---------------------------------------------------------------------------
 848 dnl CF_CURSES_UNCTRL_H version: 3 updated: 2013/11/03 06:26:10
 849 dnl ------------------
 850 dnl Any X/Open curses implementation must have unctrl.h, but ncurses packages
 851 dnl may put it in a subdirectory (along with ncurses' other headers, of
 852 dnl course).  Packages which put the headers in inconsistent locations are
 853 dnl broken).
 854 AC_DEFUN([CF_CURSES_UNCTRL_H],
 855 [
 856 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 857
 858 AC_CACHE_CHECK(for unctrl.h, cf_cv_unctrl_header,[
 859
 860 # If we found <ncurses/curses.h>, look for <ncurses/unctrl.h>, but always look
 861 # for <unctrl.h> if we do not find the variant.
 862
 863 cf_header_list="unctrl.h ncurses/unctrl.h ncursesw/unctrl.h"
 864
 865 case ${cf_cv_ncurses_header:-curses.h} in #(vi
 866 */*)
 867         cf_header_item=`echo ${cf_cv_ncurses_header:-curses.h} | sed -e 's%\..*%%' -e 's%/.*%/%'`unctrl.h
 868         cf_header_list="$cf_header_item $cf_header_list"
 869         ;;
 870 esac
 871
 872 for cf_header in $cf_header_list
 873 do
 874         AC_TRY_COMPILE([
 875 #include <${cf_cv_ncurses_header:-curses.h}>
 876 #include <${cf_header}>],
 877         [WINDOW *x],
 878         [cf_cv_unctrl_header=$cf_header
 879          break],
 880         [cf_cv_unctrl_header=no])
 881 done
 882 ])
 883
 884 case $cf_cv_unctrl_header in #(vi
 885 no)
 886         AC_MSG_WARN(unctrl.h header not found)
 887         ;;
 888 esac
 889
 890 case $cf_cv_unctrl_header in #(vi
 891 unctrl.h) #(vi
 892         AC_DEFINE(HAVE_UNCTRL_H,1,[Define to 1 if we have unctrl.h])
 893         ;;
 894 ncurses/unctrl.h) #(vi
 895         AC_DEFINE(HAVE_NCURSES_UNCTRL_H,1,[Define to 1 if we have ncurses/unctrl.h])
 896         ;;
 897 ncursesw/unctrl.h)
 898         AC_DEFINE(HAVE_NCURSESW_UNCTRL_H,1,[Define to 1 if we have ncursesw/unctrl.h])
 899         ;;
 900 esac
 901 ])dnl
 902 dnl ---------------------------------------------------------------------------
 903 dnl CF_CURSES_WACS_MAP version: 6 updated: 2012/10/06 08:57:51
 904 dnl ------------------
 905 dnl Check for likely values of wacs_map[].
 906 AC_DEFUN([CF_CURSES_WACS_MAP],
 907 [
 908 AC_CACHE_CHECK(for wide alternate character set array, cf_cv_curses_wacs_map,[
 909         cf_cv_curses_wacs_map=unknown
 910         for name in wacs_map _wacs_map __wacs_map _nc_wacs _wacs_char
 911         do
 912         AC_TRY_LINK([
 913 #ifndef _XOPEN_SOURCE_EXTENDED
 914 #define _XOPEN_SOURCE_EXTENDED
 915 #endif
 916 #include <${cf_cv_ncurses_header:-curses.h}>],
 917         [void *foo = &($name['k'])],
 918         [cf_cv_curses_wacs_map=$name
 919          break])
 920         done])
 921
 922 test "$cf_cv_curses_wacs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_WACS_ARRAY,$cf_cv_curses_wacs_map,[Define to name of (n)curses wide-character array])
 923 ])dnl
 924 dnl ---------------------------------------------------------------------------
 925 dnl CF_CURSES_WACS_SYMBOLS version: 2 updated: 2012/10/06 08:57:51
 926 dnl ----------------------
 927 dnl Do a check to see if the WACS_xxx constants are defined compatibly with
 928 dnl X/Open Curses.  In particular, NetBSD's implementation of the WACS_xxx
 929 dnl constants is broken since those constants do not point to cchar_t's.
 930 AC_DEFUN([CF_CURSES_WACS_SYMBOLS],
 931 [
 932 AC_REQUIRE([CF_CURSES_WACS_MAP])
 933
 934 AC_CACHE_CHECK(for wide alternate character constants, cf_cv_curses_wacs_symbols,[
 935 cf_cv_curses_wacs_symbols=no
 936 if test "$cf_cv_curses_wacs_map" != unknown
 937 then
 938         AC_TRY_LINK([
 939 #ifndef _XOPEN_SOURCE_EXTENDED
 940 #define _XOPEN_SOURCE_EXTENDED
 941 #endif
 942 #include <${cf_cv_ncurses_header:-curses.h}>],
 943         [cchar_t *foo = WACS_PLUS;
 944          $cf_cv_curses_wacs_map['k'] = *WACS_PLUS],
 945         [cf_cv_curses_wacs_symbols=yes])
 946 else
 947         AC_TRY_LINK([
 948 #ifndef _XOPEN_SOURCE_EXTENDED
 949 #define _XOPEN_SOURCE_EXTENDED
 950 #endif
 951 #include <${cf_cv_ncurses_header:-curses.h}>],
 952         [cchar_t *foo = WACS_PLUS],
 953         [cf_cv_curses_wacs_symbols=yes])
 954 fi
 955 ])
 956
 957 test "$cf_cv_curses_wacs_symbols" != no && AC_DEFINE(CURSES_WACS_SYMBOLS,1,[Define to 1 if (n)curses supports wide-character WACS_ symbols])
 958 ])dnl
 959 dnl ---------------------------------------------------------------------------
 960 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
 961 dnl ----------
 962 dnl "dirname" is not portable, so we fake it with a shell script.
 963 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
 964 dnl ---------------------------------------------------------------------------
 965 dnl CF_DISABLE_ECHO version: 12 updated: 2012/10/06 16:30:28
 966 dnl ---------------
 967 dnl You can always use "make -n" to see the actual options, but it's hard to
 968 dnl pick out/analyze warning messages when the compile-line is long.
 969 dnl
 970 dnl Sets:
 971 dnl     ECHO_LT - symbol to control if libtool is verbose
 972 dnl     ECHO_LD - symbol to prefix "cc -o" lines
 973 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
 974 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
 975 dnl     ECHO_CC - symbol to put before any "cc" line
 976 dnl
 977 AC_DEFUN([CF_DISABLE_ECHO],[
 978 AC_MSG_CHECKING(if you want to see long compiling messages)
 979 CF_ARG_DISABLE(echo,
 980         [  --disable-echo          do not display "compiling" commands],
 981         [
 982     ECHO_LT='--silent'
 983     ECHO_LD='@echo linking [$]@;'
 984     RULE_CC='@echo compiling [$]<'
 985     SHOW_CC='@echo compiling [$]@'
 986     ECHO_CC='@'
 987 ],[
 988     ECHO_LT=''
 989     ECHO_LD=''
 990     RULE_CC=''
 991     SHOW_CC=''
 992     ECHO_CC=''
 993 ])
 994 AC_MSG_RESULT($enableval)
 995 AC_SUBST(ECHO_LT)
 996 AC_SUBST(ECHO_LD)
 997 AC_SUBST(RULE_CC)
 998 AC_SUBST(SHOW_CC)
 999 AC_SUBST(ECHO_CC)
1000 ])dnl
1001 dnl ---------------------------------------------------------------------------
1002 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1003 dnl ----------------
1004 dnl Combine no-leak checks with the libraries or tools that are used for the
1005 dnl checks.
1006 AC_DEFUN([CF_DISABLE_LEAKS],[
1007
1008 AC_REQUIRE([CF_WITH_DMALLOC])
1009 AC_REQUIRE([CF_WITH_DBMALLOC])
1010 AC_REQUIRE([CF_WITH_VALGRIND])
1011
1012 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1013 AC_ARG_ENABLE(leaks,
1014         [  --disable-leaks         test: free permanent memory, analyze leaks],
1015         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1016         : ${with_no_leaks:=no})
1017 AC_MSG_RESULT($with_no_leaks)
1018
1019 if test "$with_no_leaks" = yes ; then
1020         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1021         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1022 fi
1023 ])dnl
1024 dnl ---------------------------------------------------------------------------
1025 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1026 dnl ---------------------
1027 dnl The rpath-hack makes it simpler to build programs, particularly with the
1028 dnl *BSD ports which may have essential libraries in unusual places.  But it
1029 dnl can interfere with building an executable for the base system.  Use this
1030 dnl option in that case.
1031 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1032 [
1033 AC_MSG_CHECKING(if rpath-hack should be disabled)
1034 CF_ARG_DISABLE(rpath-hack,
1035         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1036         [cf_disable_rpath_hack=yes],
1037         [cf_disable_rpath_hack=no])
1038 AC_MSG_RESULT($cf_disable_rpath_hack)
1039 if test "$cf_disable_rpath_hack" = no ; then
1040         CF_RPATH_HACK
1041 fi
1042 ])
1043 dnl ---------------------------------------------------------------------------
1044 dnl CF_ENABLE_WARNINGS version: 4 updated: 2009/07/26 17:53:03
1045 dnl ------------------
1046 dnl Configure-option to enable gcc warnings
1047 AC_DEFUN([CF_ENABLE_WARNINGS],[
1048 if ( test "$GCC" = yes || test "$GXX" = yes )
1049 then
1050 AC_MSG_CHECKING(if you want to turn on gcc warnings)
1051 CF_ARG_ENABLE(warnings,
1052         [  --enable-warnings       test: turn on gcc compiler warnings],
1053         [with_warnings=yes],
1054         [with_warnings=no])
1055 AC_MSG_RESULT($with_warnings)
1056 if test "$with_warnings" = "yes"
1057 then
1058         CF_GCC_ATTRIBUTES
1059         CF_GCC_WARNINGS
1060 fi
1061 fi
1062 ])dnl
1063 dnl ---------------------------------------------------------------------------
1064 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
1065 dnl ---------------
1066 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
1067 dnl prefer a standard location, and use -L options only if we do not find the
1068 dnl library in the standard library location(s).
1069 dnl     $1 = library name
1070 dnl     $2 = library class, usually the same as library name
1071 dnl     $3 = includes
1072 dnl     $4 = code fragment to compile/link
1073 dnl     $5 = corresponding function-name
1074 dnl     $6 = flag, nonnull if failure should not cause an error-exit
1075 dnl
1076 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
1077 dnl to use a -L option.
1078 AC_DEFUN([CF_FIND_LIBRARY],
1079 [
1080         eval 'cf_cv_have_lib_'$1'=no'
1081         cf_libdir=""
1082         AC_CHECK_FUNC($5,
1083                 eval 'cf_cv_have_lib_'$1'=yes',[
1084                 cf_save_LIBS="$LIBS"
1085                 AC_MSG_CHECKING(for $5 in -l$1)
1086                 LIBS="-l$1 $LIBS"
1087                 AC_TRY_LINK([$3],[$4],
1088                         [AC_MSG_RESULT(yes)
1089                          eval 'cf_cv_have_lib_'$1'=yes'
1090                         ],
1091                         [AC_MSG_RESULT(no)
1092                         CF_LIBRARY_PATH(cf_search,$2)
1093                         for cf_libdir in $cf_search
1094                         do
1095                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
1096                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
1097                                 AC_TRY_LINK([$3],[$4],
1098                                         [AC_MSG_RESULT(yes)
1099                                          eval 'cf_cv_have_lib_'$1'=yes'
1100                                          break],
1101                                         [AC_MSG_RESULT(no)
1102                                          LIBS="$cf_save_LIBS"])
1103                         done
1104                         ])
1105                 ])
1106 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
1107 ifelse($6,,[
1108 if test $cf_found_library = no ; then
1109         AC_MSG_ERROR(Cannot link $1 library)
1110 fi
1111 ])
1112 ])dnl
1113 dnl ---------------------------------------------------------------------------
1114 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1115 dnl ---------------
1116 dnl Find a library (specifically the linkage used in the code fragment),
1117 dnl searching for it if it is not already in the library path.
1118 dnl See also CF_ADD_SEARCHPATH.
1119 dnl
1120 dnl Parameters (4-on are optional):
1121 dnl     $1 = headers for library entrypoint
1122 dnl     $2 = code fragment for library entrypoint
1123 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1124 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1125 dnl     $5 = action to perform if not successful
1126 dnl     $6 = module name, if not the same as the library name
1127 dnl     $7 = extra libraries
1128 dnl
1129 dnl Sets these variables:
1130 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1131 dnl     $cf_cv_header_path_$3 - include-directory if needed
1132 dnl     $cf_cv_library_path_$3 - library-directory if needed
1133 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1134 AC_DEFUN([CF_FIND_LINKAGE],[
1135
1136 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1137 # will be set on completion of the AC_TRY_LINK below.
1138 cf_cv_header_path_$3=
1139 cf_cv_library_path_$3=
1140
1141 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1142
1143 cf_save_LIBS="$LIBS"
1144
1145 AC_TRY_LINK([$1],[$2],[
1146         cf_cv_find_linkage_$3=yes
1147         cf_cv_header_path_$3=/usr/include
1148         cf_cv_library_path_$3=/usr/lib
1149 ],[
1150
1151 LIBS="-l$3 $7 $cf_save_LIBS"
1152
1153 AC_TRY_LINK([$1],[$2],[
1154         cf_cv_find_linkage_$3=yes
1155         cf_cv_header_path_$3=/usr/include
1156         cf_cv_library_path_$3=/usr/lib
1157         cf_cv_library_file_$3="-l$3"
1158 ],[
1159         cf_cv_find_linkage_$3=no
1160         LIBS="$cf_save_LIBS"
1161
1162     CF_VERBOSE(find linkage for $3 library)
1163     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1164
1165     cf_save_CPPFLAGS="$CPPFLAGS"
1166     cf_test_CPPFLAGS="$CPPFLAGS"
1167
1168     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1169     for cf_cv_header_path_$3 in $cf_search
1170     do
1171       if test -d $cf_cv_header_path_$3 ; then
1172         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1173         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1174         AC_TRY_COMPILE([$1],[$2],[
1175             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1176             cf_cv_find_linkage_$3=maybe
1177             cf_test_CPPFLAGS="$CPPFLAGS"
1178             break],[
1179             CPPFLAGS="$cf_save_CPPFLAGS"
1180             ])
1181       fi
1182     done
1183
1184     if test "$cf_cv_find_linkage_$3" = maybe ; then
1185
1186       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1187
1188       cf_save_LIBS="$LIBS"
1189       cf_save_LDFLAGS="$LDFLAGS"
1190
1191       ifelse([$6],,,[
1192         CPPFLAGS="$cf_test_CPPFLAGS"
1193         LIBS="-l$3 $7 $cf_save_LIBS"
1194         AC_TRY_LINK([$1],[$2],[
1195             CF_VERBOSE(... found $3 library in system)
1196             cf_cv_find_linkage_$3=yes])
1197             CPPFLAGS="$cf_save_CPPFLAGS"
1198             LIBS="$cf_save_LIBS"
1199             ])
1200
1201       if test "$cf_cv_find_linkage_$3" != yes ; then
1202         CF_LIBRARY_PATH(cf_search,$3)
1203         for cf_cv_library_path_$3 in $cf_search
1204         do
1205           if test -d $cf_cv_library_path_$3 ; then
1206             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1207             CPPFLAGS="$cf_test_CPPFLAGS"
1208             LIBS="-l$3 $7 $cf_save_LIBS"
1209             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1210             AC_TRY_LINK([$1],[$2],[
1211                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1212                 cf_cv_find_linkage_$3=yes
1213                 cf_cv_library_file_$3="-l$3"
1214                 break],[
1215                 CPPFLAGS="$cf_save_CPPFLAGS"
1216                 LIBS="$cf_save_LIBS"
1217                 LDFLAGS="$cf_save_LDFLAGS"
1218                 ])
1219           fi
1220         done
1221         CPPFLAGS="$cf_save_CPPFLAGS"
1222         LDFLAGS="$cf_save_LDFLAGS"
1223       fi
1224
1225     else
1226       cf_cv_find_linkage_$3=no
1227     fi
1228     ],$7)
1229 ])
1230
1231 LIBS="$cf_save_LIBS"
1232
1233 if test "$cf_cv_find_linkage_$3" = yes ; then
1234 ifelse([$4],,[
1235         CF_ADD_INCDIR($cf_cv_header_path_$3)
1236         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1237         CF_ADD_LIB($3)
1238 ],[$4])
1239 else
1240 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1241 fi
1242 ])dnl
1243 dnl ---------------------------------------------------------------------------
1244 dnl CF_FUNC_CURSES_VERSION version: 6 updated: 2012/10/06 16:39:58
1245 dnl ----------------------
1246 dnl Solaris has a data item 'curses_version', which confuses AC_CHECK_FUNCS.
1247 dnl It's a character string "SVR4", not documented.
1248 AC_DEFUN([CF_FUNC_CURSES_VERSION],
1249 [
1250 AC_CACHE_CHECK(for function curses_version, cf_cv_func_curses_version,[
1251 AC_TRY_RUN([
1252 #include <${cf_cv_ncurses_header:-curses.h}>
1253 int main()
1254 {
1255         char temp[1024];
1256         sprintf(temp, "%s\n", curses_version());
1257         ${cf_cv_main_return:-return}(0);
1258 }]
1259 ,[cf_cv_func_curses_version=yes]
1260 ,[cf_cv_func_curses_version=no]
1261 ,[cf_cv_func_curses_version=unknown])
1262 rm -f core])
1263 test "$cf_cv_func_curses_version" = yes && AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 if we have curses_version function])
1264 ])
1265 dnl ---------------------------------------------------------------------------
1266 dnl CF_GCC_ATTRIBUTES version: 16 updated: 2012/10/02 20:55:03
1267 dnl -----------------
1268 dnl Test for availability of useful gcc __attribute__ directives to quiet
1269 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1270 dnl to documentation, unrecognized directives cause older compilers to barf.
1271 AC_DEFUN([CF_GCC_ATTRIBUTES],
1272 [
1273 if test "$GCC" = yes
1274 then
1275 cat > conftest.i <<EOF
1276 #ifndef GCC_PRINTF
1277 #define GCC_PRINTF 0
1278 #endif
1279 #ifndef GCC_SCANF
1280 #define GCC_SCANF 0
1281 #endif
1282 #ifndef GCC_NORETURN
1283 #define GCC_NORETURN /* nothing */
1284 #endif
1285 #ifndef GCC_UNUSED
1286 #define GCC_UNUSED /* nothing */
1287 #endif
1288 EOF
1289 if test "$GCC" = yes
1290 then
1291         AC_CHECKING([for $CC __attribute__ directives])
1292 cat > conftest.$ac_ext <<EOF
1293 #line __oline__ "${as_me:-configure}"
1294 #include "confdefs.h"
1295 #include "conftest.h"
1296 #include "conftest.i"
1297 #if     GCC_PRINTF
1298 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1299 #else
1300 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1301 #endif
1302 #if     GCC_SCANF
1303 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1304 #else
1305 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1306 #endif
1307 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1308 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1309 extern void foo(void) GCC_NORETURN;
1310 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1311 EOF
1312         cf_printf_attribute=no
1313         cf_scanf_attribute=no
1314         for cf_attribute in scanf printf unused noreturn
1315         do
1316                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1317                 cf_directive="__attribute__(($cf_attribute))"
1318                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1319
1320                 case $cf_attribute in #(vi
1321                 printf) #(vi
1322                         cf_printf_attribute=yes
1323                         cat >conftest.h <<EOF
1324 #define GCC_$cf_ATTRIBUTE 1
1325 EOF
1326                         ;;
1327                 scanf) #(vi
1328                         cf_scanf_attribute=yes
1329                         cat >conftest.h <<EOF
1330 #define GCC_$cf_ATTRIBUTE 1
1331 EOF
1332                         ;;
1333                 *) #(vi
1334                         cat >conftest.h <<EOF
1335 #define GCC_$cf_ATTRIBUTE $cf_directive
1336 EOF
1337                         ;;
1338                 esac
1339
1340                 if AC_TRY_EVAL(ac_compile); then
1341                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1342                         cat conftest.h >>confdefs.h
1343                         case $cf_attribute in #(vi
1344                         noreturn) #(vi
1345                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1346                                 ;;
1347                         printf) #(vi
1348                                 cf_value='/* nothing */'
1349                                 if test "$cf_printf_attribute" != no ; then
1350                                         cf_value='__attribute__((format(printf,fmt,var)))'
1351                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1352                                 fi
1353                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1354                                 ;;
1355                         scanf) #(vi
1356                                 cf_value='/* nothing */'
1357                                 if test "$cf_scanf_attribute" != no ; then
1358                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1359                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1360                                 fi
1361                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1362                                 ;;
1363                         unused) #(vi
1364                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1365                                 ;;
1366                         esac
1367                 fi
1368         done
1369 else
1370         fgrep define conftest.i >>confdefs.h
1371 fi
1372 rm -rf conftest*
1373 fi
1374 ])dnl
1375 dnl ---------------------------------------------------------------------------
1376 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1377 dnl --------------
1378 dnl Find version of gcc
1379 AC_DEFUN([CF_GCC_VERSION],[
1380 AC_REQUIRE([AC_PROG_CC])
1381 GCC_VERSION=none
1382 if test "$GCC" = yes ; then
1383         AC_MSG_CHECKING(version of $CC)
1384         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1385         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1386         AC_MSG_RESULT($GCC_VERSION)
1387 fi
1388 ])dnl
1389 dnl ---------------------------------------------------------------------------
1390 dnl CF_GCC_WARNINGS version: 31 updated: 2013/11/19 19:23:35
1391 dnl ---------------
1392 dnl Check if the compiler supports useful warning options.  There's a few that
1393 dnl we don't use, simply because they're too noisy:
1394 dnl
1395 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1396 dnl     -Wredundant-decls (system headers make this too noisy)
1397 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1398 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1399 dnl             is enabled for ncurses using "--enable-const".
1400 dnl     -pedantic
1401 dnl
1402 dnl Parameter:
1403 dnl     $1 is an optional list of gcc warning flags that a particular
1404 dnl             application might want to use, e.g., "no-unused" for
1405 dnl             -Wno-unused
1406 dnl Special:
1407 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1408 dnl
1409 AC_DEFUN([CF_GCC_WARNINGS],
1410 [
1411 AC_REQUIRE([CF_GCC_VERSION])
1412 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1413 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1414
1415 cat > conftest.$ac_ext <<EOF
1416 #line __oline__ "${as_me:-configure}"
1417 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1418 EOF
1419
1420 if test "$INTEL_COMPILER" = yes
1421 then
1422 # The "-wdXXX" options suppress warnings:
1423 # remark #1419: external declaration in primary source file
1424 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1425 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1426 # remark #193: zero used for undefined preprocessing identifier
1427 # remark #593: variable "curs_sb_left_arrow" was set but never used
1428 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1429 # remark #869: parameter "tw" was never referenced
1430 # remark #981: operands are evaluated in unspecified order
1431 # warning #279: controlling expression is constant
1432
1433         AC_CHECKING([for $CC warning options])
1434         cf_save_CFLAGS="$CFLAGS"
1435         EXTRA_CFLAGS="-Wall"
1436         for cf_opt in \
1437                 wd1419 \
1438                 wd1683 \
1439                 wd1684 \
1440                 wd193 \
1441                 wd593 \
1442                 wd279 \
1443                 wd810 \
1444                 wd869 \
1445                 wd981
1446         do
1447                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1448                 if AC_TRY_EVAL(ac_compile); then
1449                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1450                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1451                 fi
1452         done
1453         CFLAGS="$cf_save_CFLAGS"
1454
1455 elif test "$GCC" = yes
1456 then
1457         AC_CHECKING([for $CC warning options])
1458         cf_save_CFLAGS="$CFLAGS"
1459         EXTRA_CFLAGS=
1460         cf_warn_CONST=""
1461         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1462         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1463         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1464         for cf_opt in W Wall \
1465                 Wbad-function-cast \
1466                 Wcast-align \
1467                 Wcast-qual \
1468                 Wdeclaration-after-statement \
1469                 Wextra \
1470                 Winline \
1471                 Wmissing-declarations \
1472                 Wmissing-prototypes \
1473                 Wnested-externs \
1474                 Wpointer-arith \
1475                 Wshadow \
1476                 Wstrict-prototypes \
1477                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
1478         do
1479                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1480                 if AC_TRY_EVAL(ac_compile); then
1481                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1482                         case $cf_opt in #(vi
1483                         Wcast-qual) #(vi
1484                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1485                                 ;;
1486                         Winline) #(vi
1487                                 case $GCC_VERSION in
1488                                 [[34]].*)
1489                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1490                                         continue;;
1491                                 esac
1492                                 ;;
1493                         Wpointer-arith) #(vi
1494                                 case $GCC_VERSION in
1495                                 [[12]].*)
1496                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1497                                         continue;;
1498                                 esac
1499                                 ;;
1500                         esac
1501                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1502                 fi
1503         done
1504         CFLAGS="$cf_save_CFLAGS"
1505 fi
1506 rm -rf conftest*
1507
1508 AC_SUBST(EXTRA_CFLAGS)
1509 ])dnl
1510 dnl ---------------------------------------------------------------------------
1511 dnl CF_GETOPT_HEADER version: 5 updated: 2012/10/06 16:39:58
1512 dnl ----------------
1513 dnl Check for getopt's variables which are commonly defined in stdlib.h,
1514 dnl unistd.h or (nonstandard) in getopt.h
1515 AC_DEFUN([CF_GETOPT_HEADER],
1516 [
1517 AC_HAVE_HEADERS(unistd.h getopt.h)
1518 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
1519 cf_cv_getopt_header=none
1520 for cf_header in stdio.h stdlib.h unistd.h getopt.h
1521 do
1522 AC_TRY_COMPILE([
1523 #include <$cf_header>],
1524 [int x = optind; char *y = optarg],
1525 [cf_cv_getopt_header=$cf_header
1526  break])
1527 done
1528 ])
1529 if test $cf_cv_getopt_header != none ; then
1530         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if we need to include getopt.h])
1531 fi
1532 ])dnl
1533 dnl ---------------------------------------------------------------------------
1534 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
1535 dnl -------------
1536 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1537 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1538 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1539 dnl since it is interwoven with GNU extensions.
1540 dnl
1541 dnl Well, yes we could work around it...
1542 AC_DEFUN([CF_GNU_SOURCE],
1543 [
1544 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1545 AC_TRY_COMPILE([#include <sys/types.h>],[
1546 #ifndef _XOPEN_SOURCE
1547 make an error
1548 #endif],
1549         [cf_cv_gnu_source=no],
1550         [cf_save="$CPPFLAGS"
1551          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1552          AC_TRY_COMPILE([#include <sys/types.h>],[
1553 #ifdef _XOPEN_SOURCE
1554 make an error
1555 #endif],
1556         [cf_cv_gnu_source=no],
1557         [cf_cv_gnu_source=yes])
1558         CPPFLAGS="$cf_save"
1559         ])
1560 ])
1561 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1562 ])dnl
1563 dnl ---------------------------------------------------------------------------
1564 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
1565 dnl --------------
1566 dnl Construct a search-list of directories for a nonstandard header-file
1567 dnl
1568 dnl Parameters
1569 dnl     $1 = the variable to return as result
1570 dnl     $2 = the package name
1571 AC_DEFUN([CF_HEADER_PATH],
1572 [
1573 $1=
1574
1575 # collect the current set of include-directories from compiler flags
1576 cf_header_path_list=""
1577 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1578         for cf_header_path in $CPPFLAGS $CFLAGS
1579         do
1580                 case $cf_header_path in #(vi
1581                 -I*)
1582                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1583                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1584                         cf_header_path_list="$cf_header_path_list [$]$1"
1585                         ;;
1586                 esac
1587         done
1588 fi
1589
1590 # add the variations for the package we are looking for
1591 CF_SUBDIR_PATH($1,$2,include)
1592
1593 test "$includedir" != NONE && \
1594 test "$includedir" != "/usr/include" && \
1595 test -d "$includedir" && {
1596         test -d $includedir &&    $1="[$]$1 $includedir"
1597         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1598 }
1599
1600 test "$oldincludedir" != NONE && \
1601 test "$oldincludedir" != "/usr/include" && \
1602 test -d "$oldincludedir" && {
1603         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1604         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1605 }
1606
1607 $1="[$]$1 $cf_header_path_list"
1608 ])dnl
1609 dnl ---------------------------------------------------------------------------
1610 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
1611 dnl ---------------
1612 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1613 AC_DEFUN([CF_HELP_MESSAGE],
1614 [AC_DIVERT_HELP([$1])dnl
1615 ])dnl
1616 dnl ---------------------------------------------------------------------------
1617 dnl CF_INHERIT_SCRIPT version: 2 updated: 2003/03/01 23:50:42
1618 dnl -----------------
1619 dnl If we do not have a given script, look for it in the parent directory.
1620 AC_DEFUN([CF_INHERIT_SCRIPT],
1621 [
1622 test -f $1 || ( test -f ../$1 && cp ../$1 ./ )
1623 ])dnl
1624 dnl ---------------------------------------------------------------------------
1625 dnl CF_INTEL_COMPILER version: 6 updated: 2014/03/17 13:13:07
1626 dnl -----------------
1627 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1628 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1629 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1630 dnl
1631 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1632 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1633 dnl the wrappers for gcc and g++ warnings.
1634 dnl
1635 dnl $1 = GCC (default) or GXX
1636 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1637 dnl $3 = CFLAGS (default) or CXXFLAGS
1638 AC_DEFUN([CF_INTEL_COMPILER],[
1639 AC_REQUIRE([AC_CANONICAL_HOST])
1640 ifelse([$2],,INTEL_COMPILER,[$2])=no
1641
1642 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1643         case $host_os in
1644         linux*|gnu*)
1645                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1646                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1647                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1648                 AC_TRY_COMPILE([],[
1649 #ifdef __INTEL_COMPILER
1650 #else
1651 make an error
1652 #endif
1653 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1654 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
1655 ],[])
1656                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1657                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1658                 ;;
1659         esac
1660 fi
1661 ])dnl
1662 dnl ---------------------------------------------------------------------------
1663 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
1664 dnl ---------------
1665 dnl For the given system and compiler, find the compiler flags to pass to the
1666 dnl loader to use the "rpath" feature.
1667 AC_DEFUN([CF_LD_RPATH_OPT],
1668 [
1669 AC_REQUIRE([CF_CHECK_CACHE])
1670
1671 LD_RPATH_OPT=
1672 AC_MSG_CHECKING(for an rpath option)
1673 case $cf_cv_system_name in #(vi
1674 irix*) #(vi
1675         if test "$GCC" = yes; then
1676                 LD_RPATH_OPT="-Wl,-rpath,"
1677         else
1678                 LD_RPATH_OPT="-rpath "
1679         fi
1680         ;;
1681 linux*|gnu*|k*bsd*-gnu) #(vi
1682         LD_RPATH_OPT="-Wl,-rpath,"
1683         ;;
1684 openbsd[[2-9]].*|mirbsd*) #(vi
1685         LD_RPATH_OPT="-Wl,-rpath,"
1686         ;;
1687 dragonfly*|freebsd*) #(vi
1688         LD_RPATH_OPT="-rpath "
1689         ;;
1690 netbsd*) #(vi
1691         LD_RPATH_OPT="-Wl,-rpath,"
1692         ;;
1693 osf*|mls+*) #(vi
1694         LD_RPATH_OPT="-rpath "
1695         ;;
1696 solaris2*) #(vi
1697         LD_RPATH_OPT="-R"
1698         ;;
1699 *)
1700         ;;
1701 esac
1702 AC_MSG_RESULT($LD_RPATH_OPT)
1703
1704 case "x$LD_RPATH_OPT" in #(vi
1705 x-R*)
1706         AC_MSG_CHECKING(if we need a space after rpath option)
1707         cf_save_LIBS="$LIBS"
1708         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1709         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1710         LIBS="$cf_save_LIBS"
1711         AC_MSG_RESULT($cf_rpath_space)
1712         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1713         ;;
1714 esac
1715 ])dnl
1716 dnl ---------------------------------------------------------------------------
1717 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
1718 dnl ---------------
1719 dnl Construct a search-list of directories for a nonstandard library-file
1720 dnl
1721 dnl Parameters
1722 dnl     $1 = the variable to return as result
1723 dnl     $2 = the package name
1724 AC_DEFUN([CF_LIBRARY_PATH],
1725 [
1726 $1=
1727 cf_library_path_list=""
1728 if test -n "${LDFLAGS}${LIBS}" ; then
1729         for cf_library_path in $LDFLAGS $LIBS
1730         do
1731                 case $cf_library_path in #(vi
1732                 -L*)
1733                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1734                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1735                         cf_library_path_list="$cf_library_path_list [$]$1"
1736                         ;;
1737                 esac
1738         done
1739 fi
1740
1741 CF_SUBDIR_PATH($1,$2,lib)
1742
1743 $1="$cf_library_path_list [$]$1"
1744 ])dnl
1745 dnl ---------------------------------------------------------------------------
1746 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
1747 dnl ------------
1748 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
1749 dnl a monocase filesystem.
1750 AC_DEFUN([CF_MAKE_TAGS],[
1751 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
1752
1753 AC_CHECK_PROGS(CTAGS, exctags ctags)
1754 AC_CHECK_PROGS(ETAGS, exetags etags)
1755
1756 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
1757
1758 if test "$cf_cv_mixedcase" = yes ; then
1759         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
1760 else
1761         MAKE_UPPER_TAGS=no
1762 fi
1763
1764 if test "$MAKE_UPPER_TAGS" = yes ; then
1765         MAKE_UPPER_TAGS=
1766 else
1767         MAKE_UPPER_TAGS="#"
1768 fi
1769
1770 if test "$MAKE_LOWER_TAGS" = yes ; then
1771         MAKE_LOWER_TAGS=
1772 else
1773         MAKE_LOWER_TAGS="#"
1774 fi
1775
1776 AC_SUBST(CTAGS)
1777 AC_SUBST(ETAGS)
1778
1779 AC_SUBST(MAKE_UPPER_TAGS)
1780 AC_SUBST(MAKE_LOWER_TAGS)
1781 ])dnl
1782 dnl ---------------------------------------------------------------------------
1783 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
1784 dnl -----------
1785 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
1786 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
1787 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
1788 AC_DEFUN([CF_MATH_LIB],
1789 [
1790 AC_CACHE_CHECK(if -lm needed for math functions,
1791         cf_cv_need_libm,[
1792         AC_TRY_LINK([
1793         #include <stdio.h>
1794         #include <math.h>
1795         ],
1796         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
1797         [cf_cv_need_libm=no],
1798         [cf_cv_need_libm=yes])])
1799 if test "$cf_cv_need_libm" = yes
1800 then
1801 ifelse($1,,[
1802         CF_ADD_LIB(m)
1803 ],[$1=-lm])
1804 fi
1805 ])
1806 dnl ---------------------------------------------------------------------------
1807 dnl CF_MIXEDCASE_FILENAMES version: 6 updated: 2013/10/08 17:47:05
1808 dnl ----------------------
1809 dnl Check if the file-system supports mixed-case filenames.  If we're able to
1810 dnl create a lowercase name and see it as uppercase, it doesn't support that.
1811 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
1812 [
1813 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
1814 if test "$cross_compiling" = yes ; then
1815         case $target_alias in #(vi
1816         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*) #(vi
1817                 cf_cv_mixedcase=no
1818                 ;;
1819         *)
1820                 cf_cv_mixedcase=yes
1821                 ;;
1822         esac
1823 else
1824         rm -f conftest CONFTEST
1825         echo test >conftest
1826         if test -f CONFTEST ; then
1827                 cf_cv_mixedcase=no
1828         else
1829                 cf_cv_mixedcase=yes
1830         fi
1831         rm -f conftest CONFTEST
1832 fi
1833 ])
1834 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
1835 ])dnl
1836 dnl ---------------------------------------------------------------------------
1837 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
1838 dnl ----------
1839 dnl Write a debug message to config.log, along with the line number in the
1840 dnl configure script.
1841 AC_DEFUN([CF_MSG_LOG],[
1842 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
1843 ])dnl
1844 dnl ---------------------------------------------------------------------------
1845 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
1846 dnl -------------------
1847 dnl Check if we can compile with ncurses' header file
1848 dnl $1 is the cache variable to set
1849 dnl $2 is the header-file to include
1850 dnl $3 is the root name (ncurses or ncursesw)
1851 AC_DEFUN([CF_NCURSES_CC_CHECK],[
1852         AC_TRY_COMPILE([
1853 ]ifelse($3,ncursesw,[
1854 #define _XOPEN_SOURCE_EXTENDED
1855 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
1856 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
1857 ])[
1858 #include <$2>],[
1859 #ifdef NCURSES_VERSION
1860 ]ifelse($3,ncursesw,[
1861 #ifndef WACS_BSSB
1862         make an error
1863 #endif
1864 ])[
1865 printf("%s\n", NCURSES_VERSION);
1866 #else
1867 #ifdef __NCURSES_H
1868 printf("old\n");
1869 #else
1870         make an error
1871 #endif
1872 #endif
1873         ]
1874         ,[$1=$2]
1875         ,[$1=no])
1876 ])dnl
1877 dnl ---------------------------------------------------------------------------
1878 dnl CF_NCURSES_CONFIG version: 10 updated: 2012/10/06 08:57:51
1879 dnl -----------------
1880 dnl Tie together the configure-script macros for ncurses.
1881 dnl Prefer the "-config" script from ncurses 6.x, to simplify analysis.
1882 dnl Allow that to be overridden using the $NCURSES_CONFIG environment variable.
1883 dnl
1884 dnl $1 is the root library name (default: "ncurses")
1885 AC_DEFUN([CF_NCURSES_CONFIG],
1886 [
1887 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
1888
1889 echo "Looking for ${cf_ncuconfig_root}-config"
1890
1891 CF_ACVERSION_CHECK(2.52,
1892         [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
1893         [AC_PATH_PROGS(NCURSES_CONFIG, ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
1894
1895 if test "$NCURSES_CONFIG" != none ; then
1896
1897 CPPFLAGS="$CPPFLAGS `$NCURSES_CONFIG --cflags`"
1898 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
1899
1900 # even with config script, some packages use no-override for curses.h
1901 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
1902
1903 dnl like CF_NCURSES_CPPFLAGS
1904 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
1905
1906 dnl like CF_NCURSES_LIBS
1907 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
1908 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
1909
1910 dnl like CF_NCURSES_VERSION
1911 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
1912
1913 else
1914
1915 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
1916 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
1917
1918 fi
1919 ])dnl
1920 dnl ---------------------------------------------------------------------------
1921 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
1922 dnl -------------------
1923 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
1924 dnl the CPPFLAGS variable so we can include its header.
1925 dnl
1926 dnl The header files may be installed as either curses.h, or ncurses.h (would
1927 dnl be obsolete, except that some packagers prefer this name to distinguish it
1928 dnl from a "native" curses implementation).  If not installed for overwrite,
1929 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
1930 dnl /usr/include/ncurses), but someone may have installed overwriting the
1931 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
1932 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
1933 dnl the header.
1934 dnl
1935 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
1936 dnl is already in the include-path, don't even bother with this, since we cannot
1937 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
1938 dnl
1939 dnl The optional parameter gives the root name of the library, in case it is
1940 dnl not installed as the default curses library.  That is how the
1941 dnl wide-character version of ncurses is installed.
1942 AC_DEFUN([CF_NCURSES_CPPFLAGS],
1943 [AC_REQUIRE([CF_WITH_CURSES_DIR])
1944
1945 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
1946 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
1947
1948 test -n "$cf_cv_curses_dir" && \
1949 test "$cf_cv_curses_dir" != "no" && { \
1950   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
1951 }
1952
1953 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
1954         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
1955         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
1956         for cf_header in $cf_header_list
1957         do
1958                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
1959                 test "$cf_cv_ncurses_h" != no && break
1960         done
1961 ])
1962
1963 CF_NCURSES_HEADER
1964 CF_TERM_HEADER
1965
1966 # some applications need this, but should check for NCURSES_VERSION
1967 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
1968
1969 CF_NCURSES_VERSION
1970 ])dnl
1971 dnl ---------------------------------------------------------------------------
1972 dnl CF_NCURSES_EXT_FUNCS version: 4 updated: 2012/10/06 16:39:58
1973 dnl --------------------
1974 dnl Since 2007/11/17, ncurses has defined NCURSES_EXT_FUNCS; earlier versions
1975 dnl may provide these functions.  Define the symbol if it is not defined, and
1976 dnl if it is valid.
1977 AC_DEFUN([CF_NCURSES_EXT_FUNCS],
1978 [
1979 AC_CACHE_CHECK(for ncurses extended functions,cf_cv_ncurses_ext_funcs,[
1980 AC_TRY_COMPILE([
1981 #include <${cf_cv_ncurses_header:-curses.h}>],
1982 [
1983 int x = NCURSES_EXT_FUNCS
1984 ],[cf_cv_ncurses_ext_funcs=defined],[
1985 AC_TRY_LINK([
1986 #include <${cf_cv_ncurses_header:-curses.h}>],
1987 [
1988         (void) assume_default_colors (0, 0);
1989         (void) curses_version ();
1990         (void) define_key (0, 0);
1991         (void) is_term_resized (0, 0);
1992         (void) key_defined (0);
1993         (void) keybound (0, 0);
1994         (void) keyok (0, 0);
1995         (void) resize_term (0, 0);
1996         (void) resizeterm (0, 0);
1997         (void) use_default_colors ();
1998         (void) use_extended_names (0);
1999         (void) wresize (0, 0, 0);],
2000         [cf_cv_ncurses_ext_funcs=yes],
2001         [cf_cv_ncurses_ext_funcs=no])
2002 ])
2003 ])
2004 test "$cf_cv_ncurses_ext_funcs" = yes && AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 if we have ncurses extensions])
2005 ])dnl
2006 dnl ---------------------------------------------------------------------------
2007 dnl CF_NCURSES_HEADER version: 3 updated: 2012/10/06 08:57:51
2008 dnl -----------------
2009 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2010 dnl variations of ncurses' installs.
2011 dnl
2012 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2013 AC_DEFUN([CF_NCURSES_HEADER],[
2014
2015 if test "$cf_cv_ncurses_h" != no ; then
2016         cf_cv_ncurses_header=$cf_cv_ncurses_h
2017 else
2018
2019 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2020         test -n "$verbose" && echo
2021         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2022         test -n "$verbose" && echo search path $cf_search
2023         cf_save2_CPPFLAGS="$CPPFLAGS"
2024         for cf_incdir in $cf_search
2025         do
2026                 CF_ADD_INCDIR($cf_incdir)
2027                 for cf_header in \
2028                         ncurses.h \
2029                         curses.h
2030                 do
2031                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2032                         if test "$cf_cv_ncurses_h2" != no ; then
2033                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2034                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2035                                 break
2036                         fi
2037                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2038                 done
2039                 CPPFLAGS="$cf_save2_CPPFLAGS"
2040                 test "$cf_cv_ncurses_h2" != no && break
2041         done
2042         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2043         ])
2044
2045         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2046         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2047         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2048                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2049         fi
2050         CF_ADD_INCDIR($cf_1st_incdir)
2051
2052 fi
2053
2054 # Set definitions to allow ifdef'ing for ncurses.h
2055
2056 case $cf_cv_ncurses_header in # (vi
2057 *ncurses.h)
2058         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2059         ;;
2060 esac
2061
2062 case $cf_cv_ncurses_header in # (vi
2063 ncurses/curses.h|ncurses/ncurses.h)
2064         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2065         ;;
2066 ncursesw/curses.h|ncursesw/ncurses.h)
2067         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2068         ;;
2069 esac
2070
2071 ])dnl
2072 dnl ---------------------------------------------------------------------------
2073 dnl CF_NCURSES_LIBS version: 16 updated: 2010/11/20 17:02:38
2074 dnl ---------------
2075 dnl Look for the ncurses library.  This is a little complicated on Linux,
2076 dnl because it may be linked with the gpm (general purpose mouse) library.
2077 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2078 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2079 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2080 dnl and the linker will record a dependency.
2081 dnl
2082 dnl The optional parameter gives the root name of the library, in case it is
2083 dnl not installed as the default curses library.  That is how the
2084 dnl wide-character version of ncurses is installed.
2085 AC_DEFUN([CF_NCURSES_LIBS],
2086 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2087
2088 cf_nculib_root=ifelse($1,,ncurses,$1)
2089         # This works, except for the special case where we find gpm, but
2090         # ncurses is in a nonstandard location via $LIBS, and we really want
2091         # to link gpm.
2092 cf_ncurses_LIBS=""
2093 cf_ncurses_SAVE="$LIBS"
2094 AC_CHECK_LIB(gpm,Gpm_Open,
2095         [AC_CHECK_LIB(gpm,initscr,
2096                 [LIBS="$cf_ncurses_SAVE"],
2097                 [cf_ncurses_LIBS="-lgpm"])])
2098
2099 case $host_os in #(vi
2100 freebsd*)
2101         # This is only necessary if you are linking against an obsolete
2102         # version of ncurses (but it should do no harm, since it's static).
2103         if test "$cf_nculib_root" = ncurses ; then
2104                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2105         fi
2106         ;;
2107 esac
2108
2109 CF_ADD_LIBS($cf_ncurses_LIBS)
2110
2111 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2112 then
2113         CF_ADD_LIBS(-l$cf_nculib_root)
2114 else
2115         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2116                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2117                 [initscr()],
2118                 initscr)
2119 fi
2120
2121 if test -n "$cf_ncurses_LIBS" ; then
2122         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2123         cf_ncurses_SAVE="$LIBS"
2124         for p in $cf_ncurses_LIBS ; do
2125                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2126                 if test "$q" != "$LIBS" ; then
2127                         LIBS="$q"
2128                 fi
2129         done
2130         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2131                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2132                 [AC_MSG_RESULT(yes)],
2133                 [AC_MSG_RESULT(no)
2134                  LIBS="$cf_ncurses_SAVE"])
2135 fi
2136
2137 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2138 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2139 ])dnl
2140 dnl ---------------------------------------------------------------------------
2141 dnl CF_NCURSES_VERSION version: 14 updated: 2012/10/06 08:57:51
2142 dnl ------------------
2143 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2144 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2145 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2146 AC_DEFUN([CF_NCURSES_VERSION],
2147 [
2148 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2149 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2150         cf_cv_ncurses_version=no
2151         cf_tempfile=out$$
2152         rm -f $cf_tempfile
2153         AC_TRY_RUN([
2154 #include <${cf_cv_ncurses_header:-curses.h}>
2155 #include <stdio.h>
2156 int main()
2157 {
2158         FILE *fp = fopen("$cf_tempfile", "w");
2159 #ifdef NCURSES_VERSION
2160 # ifdef NCURSES_VERSION_PATCH
2161         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2162 # else
2163         fprintf(fp, "%s\n", NCURSES_VERSION);
2164 # endif
2165 #else
2166 # ifdef __NCURSES_H
2167         fprintf(fp, "old\n");
2168 # else
2169         make an error
2170 # endif
2171 #endif
2172         ${cf_cv_main_return:-return}(0);
2173 }],[
2174         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2175
2176         # This will not work if the preprocessor splits the line after the
2177         # Autoconf token.  The 'unproto' program does that.
2178         cat > conftest.$ac_ext <<EOF
2179 #include <${cf_cv_ncurses_header:-curses.h}>
2180 #undef Autoconf
2181 #ifdef NCURSES_VERSION
2182 Autoconf NCURSES_VERSION
2183 #else
2184 #ifdef __NCURSES_H
2185 Autoconf "old"
2186 #endif
2187 ;
2188 #endif
2189 EOF
2190         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2191         AC_TRY_EVAL(cf_try)
2192         if test -f conftest.out ; then
2193                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2194                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2195                 rm -f conftest.out
2196         fi
2197 ])
2198         rm -f $cf_tempfile
2199 ])
2200 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2201 ])dnl
2202 dnl ---------------------------------------------------------------------------
2203 dnl CF_NCURSES_WRAP_PREFIX version: 1 updated: 2009/03/28 16:08:10
2204 dnl ----------------------
2205 dnl Check for ncurses "wrap-prefix" used for public variables which have been
2206 dnl wrapped with a function to help with concurrency control.
2207 AC_DEFUN([CF_NCURSES_WRAP_PREFIX],
2208 [
2209 AC_MSG_CHECKING(for ncurses wrap-prefix)
2210 AC_ARG_WITH(ncurses-wrap-prefix,
2211         [  --with-ncurses-wrap-prefix naming-prefix for ncurses wrapped-variables],
2212         [NCURSES_WRAP_PREFIX=$withval],
2213         [NCURSES_WRAP_PREFIX=_nc_])
2214 AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
2215
2216 AC_SUBST(NCURSES_WRAP_PREFIX)
2217 ])
2218 dnl ---------------------------------------------------------------------------
2219 dnl CF_NETBSD_FORM_H version: 2 updated: 2012/10/06 16:39:58
2220 dnl ----------------
2221 dnl Check for NetBSD's form.h, which is incompatible with SVr4 and ncurses.
2222 dnl Some workarounds are needed in client programs to allow them to compile.
2223 AC_DEFUN([CF_NETBSD_FORM_H],[
2224 AC_CACHE_CHECK(for NetBSD form.h,cf_cv_netbsd_form_h,[
2225 AC_TRY_COMPILE([
2226 #include <${cf_cv_ncurses_header:-curses.h}>
2227 #include <form.h>
2228 ],[
2229         FORM *form;
2230         int y = current_field(form)->cursor_ypos;
2231         int x = current_field(form)->cursor_xpos;
2232 ],[cf_cv_netbsd_form_h=yes
2233 ],[cf_cv_netbsd_form_h=no])
2234 ])
2235
2236 test "$cf_cv_netbsd_form_h" = yes && AC_DEFINE(HAVE_NETBSD_FORM_H,1,[Define to 1 if we appear to be using NetBSD form.h])
2237 ])dnl
2238 dnl ---------------------------------------------------------------------------
2239 dnl CF_NETBSD_MENU_H version: 2 updated: 2012/10/06 16:39:58
2240 dnl ----------------
2241 dnl Check for NetBSD's menu.h, which is incompatible with SVr4 and ncurses.
2242 dnl Some workarounds are needed in client programs to allow them to compile.
2243 AC_DEFUN([CF_NETBSD_MENU_H],[
2244 AC_CACHE_CHECK(for NetBSD menu.h,cf_cv_netbsd_menu_h,[
2245 AC_TRY_COMPILE([
2246 #include <${cf_cv_ncurses_header:-curses.h}>
2247 #include <menu.h>
2248 ],[
2249         MENU *menu;
2250         int y = menu->max_item_width;
2251 ],[cf_cv_netbsd_menu_h=yes
2252 ],[cf_cv_netbsd_menu_h=no])
2253 ])
2254
2255 test "$cf_cv_netbsd_menu_h" = yes && AC_DEFINE(HAVE_NETBSD_MENU_H,1,[Define to 1 if we appear to be using NetBSD menu.h])
2256 ])dnl
2257 dnl ---------------------------------------------------------------------------
2258 dnl CF_NO_LEAKS_OPTION version: 5 updated: 2012/10/02 20:55:03
2259 dnl ------------------
2260 dnl see CF_WITH_NO_LEAKS
2261 AC_DEFUN([CF_NO_LEAKS_OPTION],[
2262 AC_MSG_CHECKING(if you want to use $1 for testing)
2263 AC_ARG_WITH($1,
2264         [$2],
2265         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
2266          $4
2267 ])
2268         : ${with_cflags:=-g}
2269         : ${with_no_leaks:=yes}
2270          with_$1=yes],
2271         [with_$1=])
2272 AC_MSG_RESULT(${with_$1:-no})
2273
2274 case .$with_cflags in #(vi
2275 .*-g*)
2276         case .$CFLAGS in #(vi
2277         .*-g*) #(vi
2278                 ;;
2279         *)
2280                 CF_ADD_CFLAGS([-g])
2281                 ;;
2282         esac
2283         ;;
2284 esac
2285 ])dnl
2286 dnl ---------------------------------------------------------------------------
2287 dnl CF_PATH_SYNTAX version: 14 updated: 2012/06/19 20:58:54
2288 dnl --------------
2289 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2290 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2291 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2292 dnl delayed evaluation of those symbols.
2293 AC_DEFUN([CF_PATH_SYNTAX],[
2294 if test "x$prefix" != xNONE; then
2295   cf_path_syntax="$prefix"
2296 else
2297   cf_path_syntax="$ac_default_prefix"
2298 fi
2299
2300 case ".[$]$1" in #(vi
2301 .\[$]\(*\)*|.\'*\'*) #(vi
2302   ;;
2303 ..|./*|.\\*) #(vi
2304   ;;
2305 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
2306   ;;
2307 .\[$]{*prefix}*|.\[$]{*dir}*) #(vi
2308   eval $1="[$]$1"
2309   case ".[$]$1" in #(vi
2310   .NONE/*)
2311     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2312     ;;
2313   esac
2314   ;; #(vi
2315 .no|.NONE/*)
2316   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2317   ;;
2318 *)
2319   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2320   ;;
2321 esac
2322 ])dnl
2323 dnl ---------------------------------------------------------------------------
2324 dnl CF_PDCURSES_X11 version: 13 updated: 2012/10/06 16:39:58
2325 dnl ---------------
2326 dnl Configure for PDCurses' X11 library
2327 AC_DEFUN([CF_PDCURSES_X11],[
2328 AC_REQUIRE([CF_X_ATHENA])
2329
2330 CF_ACVERSION_CHECK(2.52,
2331         [AC_CHECK_TOOLS(XCURSES_CONFIG, xcurses-config, none)],
2332         [AC_PATH_PROGS(XCURSES_CONFIG, xcurses-config, none)])
2333
2334 if test "$XCURSES_CONFIG" != none ; then
2335
2336 CPPFLAGS="$CPPFLAGS `$XCURSES_CONFIG --cflags`"
2337 CF_ADD_LIBS(`$XCURSES_CONFIG --libs`)
2338
2339 cf_cv_lib_XCurses=yes
2340
2341 else
2342
2343 LDFLAGS="$LDFLAGS $X_LIBS"
2344 CF_CHECK_CFLAGS($X_CFLAGS)
2345 AC_CHECK_LIB(X11,XOpenDisplay,
2346         [CF_ADD_LIBS(-lX11)],,
2347         [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])
2348 AC_CACHE_CHECK(for XCurses library,cf_cv_lib_XCurses,[
2349 CF_ADD_LIBS(-lXCurses)
2350 AC_TRY_LINK([
2351 #include <xcurses.h>
2352 char *XCursesProgramName = "test";
2353 ],[XCursesExit();],
2354 [cf_cv_lib_XCurses=yes],
2355 [cf_cv_lib_XCurses=no])
2356 ])
2357
2358 fi
2359
2360 if test $cf_cv_lib_XCurses = yes ; then
2361         AC_DEFINE(UNIX,1,[Define to 1 if using PDCurses on Unix])
2362         AC_DEFINE(XCURSES,1,[Define to 1 if using PDCurses on Unix])
2363         AC_CHECK_HEADER(xcurses.h, AC_DEFINE(HAVE_XCURSES,1,[Define to 1 if using PDCurses on Unix]))
2364 else
2365         AC_MSG_ERROR(Cannot link with XCurses)
2366 fi
2367 ])dnl
2368 dnl ---------------------------------------------------------------------------
2369 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
2370 dnl -------------
2371 dnl Check for the package-config program, unless disabled by command-line.
2372 AC_DEFUN([CF_PKG_CONFIG],
2373 [
2374 AC_MSG_CHECKING(if you want to use pkg-config)
2375 AC_ARG_WITH(pkg-config,
2376         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2377         [cf_pkg_config=$withval],
2378         [cf_pkg_config=yes])
2379 AC_MSG_RESULT($cf_pkg_config)
2380
2381 case $cf_pkg_config in #(vi
2382 no) #(vi
2383         PKG_CONFIG=none
2384         ;;
2385 yes) #(vi
2386         CF_ACVERSION_CHECK(2.52,
2387                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2388                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2389         ;;
2390 *)
2391         PKG_CONFIG=$withval
2392         ;;
2393 esac
2394
2395 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2396 if test "$PKG_CONFIG" != none ; then
2397         CF_PATH_SYNTAX(PKG_CONFIG)
2398 fi
2399
2400 AC_SUBST(PKG_CONFIG)
2401 ])dnl
2402 dnl ---------------------------------------------------------------------------
2403 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
2404 dnl -----------------
2405 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2406 dnl
2407 dnl     POSIX.1-1990                            _POSIX_SOURCE
2408 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2409 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2410 dnl             Bindings Option
2411 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2412 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2413 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2414 dnl
2415 dnl Parameters:
2416 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2417 AC_DEFUN([CF_POSIX_C_SOURCE],
2418 [
2419 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2420
2421 cf_save_CFLAGS="$CFLAGS"
2422 cf_save_CPPFLAGS="$CPPFLAGS"
2423
2424 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2425 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2426
2427 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2428         CF_MSG_LOG(if the symbol is already defined go no further)
2429         AC_TRY_COMPILE([#include <sys/types.h>],[
2430 #ifndef _POSIX_C_SOURCE
2431 make an error
2432 #endif],
2433         [cf_cv_posix_c_source=no],
2434         [cf_want_posix_source=no
2435          case .$cf_POSIX_C_SOURCE in #(vi
2436          .[[12]]??*) #(vi
2437                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2438                 ;;
2439          .2) #(vi
2440                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2441                 cf_want_posix_source=yes
2442                 ;;
2443          .*)
2444                 cf_want_posix_source=yes
2445                 ;;
2446          esac
2447          if test "$cf_want_posix_source" = yes ; then
2448                 AC_TRY_COMPILE([#include <sys/types.h>],[
2449 #ifdef _POSIX_SOURCE
2450 make an error
2451 #endif],[],
2452                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2453          fi
2454          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2455          CFLAGS="$cf_trim_CFLAGS"
2456          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
2457          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2458          AC_TRY_COMPILE([#include <sys/types.h>],[
2459 #ifndef _POSIX_C_SOURCE
2460 make an error
2461 #endif],,
2462          [cf_cv_posix_c_source=no])
2463          CFLAGS="$cf_save_CFLAGS"
2464          CPPFLAGS="$cf_save_CPPFLAGS"
2465         ])
2466 ])
2467
2468 if test "$cf_cv_posix_c_source" != no ; then
2469         CFLAGS="$cf_trim_CFLAGS"
2470         CPPFLAGS="$cf_trim_CPPFLAGS"
2471         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2472 fi
2473
2474 ])dnl
2475 dnl ---------------------------------------------------------------------------
2476 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
2477 dnl ------------
2478 dnl Append definitions and rules for the given programs to the subdirectory
2479 dnl Makefiles, and the recursion rule for the top-level Makefile.
2480 dnl
2481 dnl parameters
2482 dnl     $1 = script to run
2483 dnl     $2 = list of subdirectories
2484 dnl
2485 dnl variables
2486 dnl     $AWK
2487 AC_DEFUN([CF_PRG_RULES],
2488 [
2489 for cf_dir in $2
2490 do
2491         if test ! -d $srcdir/$cf_dir; then
2492                 continue
2493         elif test -f $srcdir/$cf_dir/programs; then
2494                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
2495         fi
2496 done
2497
2498 ])dnl
2499 dnl ---------------------------------------------------------------------------
2500 dnl CF_PROG_CC version: 3 updated: 2012/10/06 15:31:55
2501 dnl ----------
2502 dnl standard check for CC, plus followup sanity checks
2503 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
2504 AC_DEFUN([CF_PROG_CC],[
2505 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
2506 CF_GCC_VERSION
2507 CF_ACVERSION_CHECK(2.52,
2508         [AC_PROG_CC_STDC],
2509         [CF_ANSI_CC_REQD])
2510 CF_CC_ENV_FLAGS
2511 ])dnl
2512 dnl ---------------------------------------------------------------------------
2513 dnl CF_PROG_INSTALL version: 5 updated: 2002/12/21 22:46:07
2514 dnl ---------------
2515 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
2516 dnl misc/tabset install won't work properly.  Usually this happens only when
2517 dnl using the fallback mkinstalldirs script
2518 AC_DEFUN([CF_PROG_INSTALL],
2519 [AC_PROG_INSTALL
2520 case $INSTALL in
2521 /*)
2522   ;;
2523 *)
2524   CF_DIRNAME(cf_dir,$INSTALL)
2525   test -z "$cf_dir" && cf_dir=.
2526   INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
2527   ;;
2528 esac
2529 ])dnl
2530 dnl ---------------------------------------------------------------------------
2531 dnl CF_PROG_LINT version: 2 updated: 2009/08/12 04:43:14
2532 dnl ------------
2533 AC_DEFUN([CF_PROG_LINT],
2534 [
2535 AC_CHECK_PROGS(LINT, tdlint lint alint splint lclint)
2536 AC_SUBST(LINT_OPTS)
2537 ])dnl
2538 dnl ---------------------------------------------------------------------------
2539 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
2540 dnl ----------------
2541 dnl Remove all -U and -D options that refer to the given symbol from a list
2542 dnl of C compiler options.  This works around the problem that not all
2543 dnl compilers process -U and -D options from left-to-right, so a -U option
2544 dnl cannot be used to cancel the effect of a preceding -D option.
2545 dnl
2546 dnl $1 = target (which could be the same as the source variable)
2547 dnl $2 = source (including '$')
2548 dnl $3 = symbol to remove
2549 define([CF_REMOVE_DEFINE],
2550 [
2551 $1=`echo "$2" | \
2552         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
2553                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
2554 ])dnl
2555 dnl ---------------------------------------------------------------------------
2556 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
2557 dnl -------------
2558 AC_DEFUN([CF_RPATH_HACK],
2559 [
2560 AC_REQUIRE([CF_LD_RPATH_OPT])
2561 AC_MSG_CHECKING(for updated LDFLAGS)
2562 if test -n "$LD_RPATH_OPT" ; then
2563         AC_MSG_RESULT(maybe)
2564
2565         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
2566         cf_rpath_list="/usr/lib /lib"
2567         if test "$cf_ldd_prog" != no
2568         then
2569                 cf_rpath_oops=
2570
2571 AC_TRY_LINK([#include <stdio.h>],
2572                 [printf("Hello");],
2573                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
2574                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
2575
2576                 # If we passed the link-test, but get a "not found" on a given library,
2577                 # this could be due to inept reconfiguration of gcc to make it only
2578                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
2579                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
2580                 # /usr/local libraries.
2581                 if test -n "$cf_rpath_oops"
2582                 then
2583                         for cf_rpath_src in $cf_rpath_oops
2584                         do
2585                                 for cf_rpath_dir in \
2586                                         /usr/local \
2587                                         /usr/pkg \
2588                                         /opt/sfw
2589                                 do
2590                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
2591                                         then
2592                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
2593                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
2594                                                 break
2595                                         fi
2596                                 done
2597                         done
2598                 fi
2599         fi
2600
2601         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
2602
2603         CF_RPATH_HACK_2(LDFLAGS)
2604         CF_RPATH_HACK_2(LIBS)
2605
2606         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
2607 else
2608         AC_MSG_RESULT(no)
2609 fi
2610 AC_SUBST(EXTRA_LDFLAGS)
2611 ])dnl
2612 dnl ---------------------------------------------------------------------------
2613 dnl CF_RPATH_HACK_2 version: 6 updated: 2010/04/17 16:31:24
2614 dnl ---------------
2615 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
2616 dnl EXTRA_LDFLAGS for each -L option found.
2617 dnl
2618 dnl $cf_rpath_list contains a list of directories to ignore.
2619 dnl
2620 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
2621 dnl      but LIBS often has misplaced -L options.
2622 AC_DEFUN([CF_RPATH_HACK_2],
2623 [
2624 CF_VERBOSE(...checking $1 [$]$1)
2625
2626 cf_rpath_dst=
2627 for cf_rpath_src in [$]$1
2628 do
2629         case $cf_rpath_src in #(vi
2630         -L*) #(vi
2631
2632                 # check if this refers to a directory which we will ignore
2633                 cf_rpath_skip=no
2634                 if test -n "$cf_rpath_list"
2635                 then
2636                         for cf_rpath_item in $cf_rpath_list
2637                         do
2638                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
2639                                 then
2640                                         cf_rpath_skip=yes
2641                                         break
2642                                 fi
2643                         done
2644                 fi
2645
2646                 if test "$cf_rpath_skip" = no
2647                 then
2648                         # transform the option
2649                         if test "$LD_RPATH_OPT" = "-R " ; then
2650                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
2651                         else
2652                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
2653                         fi
2654
2655                         # if we have not already added this, add it now
2656                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
2657                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
2658                         then
2659                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
2660                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
2661                         fi
2662                 fi
2663                 ;;
2664         esac
2665         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
2666 done
2667 $1=$cf_rpath_dst
2668
2669 CF_VERBOSE(...checked $1 [$]$1)
2670 AC_SUBST(EXTRA_LDFLAGS)
2671 ])dnl
2672 dnl ---------------------------------------------------------------------------
2673 dnl CF_SIG_ATOMIC_T version: 3 updated: 2012/10/04 20:12:20
2674 dnl ---------------
2675 dnl signal handler, but there are some gcc depedencies in that recommendation.
2676 dnl Try anyway.
2677 AC_DEFUN([CF_SIG_ATOMIC_T],
2678 [
2679 AC_MSG_CHECKING(for signal global datatype)
2680 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
2681         for cf_type in \
2682                 "volatile sig_atomic_t" \
2683                 "sig_atomic_t" \
2684                 "int"
2685         do
2686         AC_TRY_COMPILE([
2687 #include <sys/types.h>
2688 #include <signal.h>
2689 #include <stdio.h>
2690
2691 extern $cf_type x;
2692 $cf_type x;
2693 static void handler(int sig)
2694 {
2695         x = 5;
2696 }],
2697                 [signal(SIGINT, handler);
2698                  x = 1],
2699                 [cf_cv_sig_atomic_t=$cf_type],
2700                 [cf_cv_sig_atomic_t=no])
2701                 test "$cf_cv_sig_atomic_t" != no && break
2702         done
2703         ])
2704 AC_MSG_RESULT($cf_cv_sig_atomic_t)
2705 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
2706 ])dnl
2707 dnl ---------------------------------------------------------------------------
2708 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
2709 dnl --------------
2710 dnl Construct a search-list for a nonstandard header/lib-file
2711 dnl     $1 = the variable to return as result
2712 dnl     $2 = the package name
2713 dnl     $3 = the subdirectory, e.g., bin, include or lib
2714 AC_DEFUN([CF_SUBDIR_PATH],
2715 [
2716 $1=
2717
2718 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
2719 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
2720 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
2721 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
2722 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
2723 ])dnl
2724 dnl ---------------------------------------------------------------------------
2725 dnl CF_SYS_TIME_SELECT version: 5 updated: 2012/10/04 05:24:07
2726 dnl ------------------
2727 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
2728 dnl older SCO configurations.
2729 AC_DEFUN([CF_SYS_TIME_SELECT],
2730 [
2731 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
2732 AC_CACHE_VAL(cf_cv_sys_time_select,[
2733 AC_TRY_COMPILE([
2734 #include <sys/types.h>
2735 #ifdef HAVE_SYS_TIME_H
2736 #include <sys/time.h>
2737 #endif
2738 #ifdef HAVE_SYS_SELECT_H
2739 #include <sys/select.h>
2740 #endif
2741 ],[],[cf_cv_sys_time_select=yes],
2742      [cf_cv_sys_time_select=no])
2743      ])
2744 AC_MSG_RESULT($cf_cv_sys_time_select)
2745 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
2746 ])dnl
2747 dnl ---------------------------------------------------------------------------
2748 dnl CF_TERM_HEADER version: 3 updated: 2012/10/06 08:57:51
2749 dnl --------------
2750 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
2751 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
2752 dnl but some packagers change this, breaking various applications.
2753 AC_DEFUN([CF_TERM_HEADER],[
2754 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
2755 case ${cf_cv_ncurses_header} in #(vi
2756 */ncurses.h|*/ncursesw.h) #(vi
2757         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
2758         ;;
2759 *)
2760         cf_term_header=term.h
2761         ;;
2762 esac
2763
2764 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
2765 do
2766 AC_TRY_COMPILE([#include <stdio.h>
2767 #include <${cf_cv_ncurses_header:-curses.h}>
2768 #include <$cf_test>
2769 ],[int x = auto_left_margin],[
2770         cf_cv_term_header="$cf_test"],[
2771         cf_cv_term_header=unknown
2772         ])
2773         test "$cf_cv_term_header" != unknown && break
2774 done
2775 ])
2776
2777 # Set definitions to allow ifdef'ing to accommodate subdirectories
2778
2779 case $cf_cv_term_header in # (vi
2780 *term.h)
2781         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
2782         ;;
2783 esac
2784
2785 case $cf_cv_term_header in # (vi
2786 ncurses/term.h) #(vi
2787         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
2788         ;;
2789 ncursesw/term.h)
2790         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
2791         ;;
2792 esac
2793 ])dnl
2794 dnl ---------------------------------------------------------------------------
2795 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
2796 dnl ---------------
2797 dnl Define a top_builddir symbol, for applications that need an absolute path.
2798 AC_DEFUN([CF_TOP_BUILDDIR],
2799 [
2800 top_builddir=ifelse($1,,`pwd`,$1)
2801 AC_SUBST(top_builddir)
2802 ])dnl
2803 dnl ---------------------------------------------------------------------------
2804 dnl CF_TPUTS_PROTO version: 2 updated: 2011/04/23 19:25:50
2805 dnl --------------
2806 dnl Check for type of function-pointer passed to tputs.  Some old
2807 dnl implementations used functions that had different prototypes, making it
2808 dnl hard to compile portable programs using tputs.
2809 AC_DEFUN([CF_TPUTS_PROTO],[
2810 CF_CURSES_FUNCS(tputs)
2811 if test x$cf_cv_func_tputs = xyes
2812 then
2813         cf_done=no
2814         for cf_arg in int char
2815         do
2816                 for cf_ret in int void
2817                 do
2818                         if test $cf_ret = void
2819                         then
2820                                 cf_return="/* nothing */"
2821                         else
2822                                 cf_return="return value"
2823                         fi
2824                         AC_TRY_COMPILE([
2825 #include <${cf_cv_ncurses_header:-curses.h}>
2826 #include <$cf_cv_term_header>
2827
2828 static $cf_ret outc($cf_arg value) { $cf_return; }
2829 ],[
2830         tputs("hello", 0, outc);
2831         ${cf_cv_main_return:-return}(0);
2832 ],[
2833                 CF_VERBOSE([prototype $cf_ret func($cf_arg value)])
2834                 cat >>confdefs.h <<EOF
2835 #define TPUTS_ARG               $cf_arg
2836 #define TPUTS_PROTO(func,value) $cf_ret func(TPUTS_ARG value)
2837 #define TPUTS_RETURN(value)     $cf_return
2838 EOF
2839                 cf_done=yes
2840                 break
2841 ])
2842                 done
2843                 test $cf_done = yes && break
2844         done
2845 fi
2846 ])dnl
2847 dnl ---------------------------------------------------------------------------
2848 dnl CF_TRIM_X_LIBS version: 2 updated: 2013/07/09 21:27:22
2849 dnl --------------
2850 dnl Trim extra base X libraries added as a workaround for inconsistent library
2851 dnl dependencies returned by "new" pkg-config files.
2852 AC_DEFUN([CF_TRIM_X_LIBS],[
2853         for cf_trim_lib in Xmu Xt X11
2854         do
2855                 case "$LIBS" in
2856                 *-l$cf_trim_lib\ *-l$cf_trim_lib*)
2857                         LIBS=`echo "$LIBS " | sed -e 's/  / /g' -e 's%-l'"$cf_trim_lib"' %%' -e 's/ $//'`
2858                         CF_VERBOSE(..trimmed $LIBS)
2859                         ;;
2860                 esac
2861         done
2862 ])
2863 dnl ---------------------------------------------------------------------------
2864 dnl CF_TRY_PKG_CONFIG version: 5 updated: 2013/07/06 21:27:06
2865 dnl -----------------
2866 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
2867 dnl available in that form.
2868 dnl
2869 dnl $1 = package name
2870 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
2871 dnl $3 = logic to use if pkg-config does not have the package
2872 AC_DEFUN([CF_TRY_PKG_CONFIG],[
2873 AC_REQUIRE([CF_PKG_CONFIG])
2874
2875 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists $1; then
2876         CF_VERBOSE(found package $1)
2877         cf_pkgconfig_incs="`$PKG_CONFIG --cflags $1 2>/dev/null`"
2878         cf_pkgconfig_libs="`$PKG_CONFIG --libs   $1 2>/dev/null`"
2879         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
2880         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
2881         CF_ADD_CFLAGS($cf_pkgconfig_incs)
2882         CF_ADD_LIBS($cf_pkgconfig_libs)
2883         ifelse([$2],,:,[$2])
2884 else
2885         cf_pkgconfig_incs=
2886         cf_pkgconfig_libs=
2887         ifelse([$3],,:,[$3])
2888 fi
2889 ])
2890 dnl ---------------------------------------------------------------------------
2891 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
2892 dnl -------------------
2893 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
2894 dnl can define it successfully.
2895 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
2896 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
2897         AC_TRY_COMPILE([
2898 #include <stdlib.h>
2899 #include <string.h>
2900 #include <sys/types.h>
2901 ],[
2902 #ifndef _XOPEN_SOURCE
2903 make an error
2904 #endif],
2905         [cf_cv_xopen_source=no],
2906         [cf_save="$CPPFLAGS"
2907          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
2908          AC_TRY_COMPILE([
2909 #include <stdlib.h>
2910 #include <string.h>
2911 #include <sys/types.h>
2912 ],[
2913 #ifdef _XOPEN_SOURCE
2914 make an error
2915 #endif],
2916         [cf_cv_xopen_source=no],
2917         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
2918         CPPFLAGS="$cf_save"
2919         ])
2920 ])
2921
2922 if test "$cf_cv_xopen_source" != no ; then
2923         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
2924         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
2925         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
2926         CF_ADD_CFLAGS($cf_temp_xopen_source)
2927 fi
2928 ])
2929 dnl ---------------------------------------------------------------------------
2930 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
2931 dnl --------
2932 dnl Make an uppercase version of a variable
2933 dnl $1=uppercase($2)
2934 AC_DEFUN([CF_UPPER],
2935 [
2936 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
2937 ])dnl
2938 dnl ---------------------------------------------------------------------------
2939 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
2940 dnl -----------
2941 dnl Check for multibyte support, and if not found, utf8 compatibility library
2942 AC_DEFUN([CF_UTF8_LIB],
2943 [
2944 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
2945         cf_save_LIBS="$LIBS"
2946         AC_TRY_LINK([
2947 #include <stdlib.h>],[putwc(0,0);],
2948         [cf_cv_utf8_lib=yes],
2949         [CF_FIND_LINKAGE([
2950 #include <libutf8.h>],[putwc(0,0);],utf8,
2951                 [cf_cv_utf8_lib=add-on],
2952                 [cf_cv_utf8_lib=no])
2953 ])])
2954
2955 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
2956 # ncurses/ncursesw:
2957 if test "$cf_cv_utf8_lib" = "add-on" ; then
2958         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
2959         CF_ADD_INCDIR($cf_cv_header_path_utf8)
2960         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
2961         CF_ADD_LIBS($cf_cv_library_file_utf8)
2962 fi
2963 ])dnl
2964 dnl ---------------------------------------------------------------------------
2965 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
2966 dnl ----------
2967 dnl Use AC_VERBOSE w/o the warnings
2968 AC_DEFUN([CF_VERBOSE],
2969 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
2970 CF_MSG_LOG([$1])
2971 ])dnl
2972 dnl ---------------------------------------------------------------------------
2973 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
2974 dnl -------------
2975 dnl Check if type wide-character type $1 is declared, and if so, which header
2976 dnl file is needed.  The second parameter is used to set a shell variable when
2977 dnl the type is not found.  The first parameter sets a shell variable for the
2978 dnl opposite sense.
2979 AC_DEFUN([CF_WCHAR_TYPE],
2980 [
2981 # This is needed on Tru64 5.0 to declare $1
2982 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
2983 AC_TRY_COMPILE([
2984 #include <stdlib.h>
2985 #include <stdarg.h>
2986 #include <stdio.h>
2987 #ifdef HAVE_LIBUTF8_H
2988 #include <libutf8.h>
2989 #endif],
2990         [$1 state],
2991         [cf_cv_$1=no],
2992         [AC_TRY_COMPILE([
2993 #include <stdlib.h>
2994 #include <stdarg.h>
2995 #include <stdio.h>
2996 #include <wchar.h>
2997 #ifdef HAVE_LIBUTF8_H
2998 #include <libutf8.h>
2999 #endif],
3000         [$1 value],
3001         [cf_cv_$1=yes],
3002         [cf_cv_$1=unknown])])])
3003
3004 if test "$cf_cv_$1" = yes ; then
3005         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
3006         NEED_WCHAR_H=1
3007 fi
3008
3009 ifelse([$2],,,[
3010 # if we do not find $1 in either place, use substitution to provide a fallback.
3011 if test "$cf_cv_$1" = unknown ; then
3012         $2=1
3013 fi
3014 ])
3015 ifelse($3,,,[
3016 # if we find $1 in either place, use substitution to provide a fallback.
3017 if test "$cf_cv_$1" != unknown ; then
3018         $3=1
3019 fi
3020 ])
3021 ])dnl
3022 dnl ---------------------------------------------------------------------------
3023 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3024 dnl ------------------
3025 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3026 dnl libraries.
3027 AC_DEFUN([CF_WITH_CURSES_DIR],[
3028
3029 AC_MSG_CHECKING(for specific curses-directory)
3030 AC_ARG_WITH(curses-dir,
3031         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3032         [cf_cv_curses_dir=$withval],
3033         [cf_cv_curses_dir=no])
3034 AC_MSG_RESULT($cf_cv_curses_dir)
3035
3036 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3037 then
3038         CF_PATH_SYNTAX(withval)
3039         if test -d "$cf_cv_curses_dir"
3040         then
3041                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3042                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3043         fi
3044 fi
3045 ])dnl
3046 dnl ---------------------------------------------------------------------------
3047 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
3048 dnl ----------------
3049 dnl Configure-option for dbmalloc.  The optional parameter is used to override
3050 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
3051 AC_DEFUN([CF_WITH_DBMALLOC],[
3052 CF_NO_LEAKS_OPTION(dbmalloc,
3053         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
3054         [USE_DBMALLOC])
3055
3056 if test "$with_dbmalloc" = yes ; then
3057         AC_CHECK_HEADER(dbmalloc.h,
3058                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
3059 fi
3060 ])dnl
3061 dnl ---------------------------------------------------------------------------
3062 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
3063 dnl ---------------
3064 dnl Configure-option for dmalloc.  The optional parameter is used to override
3065 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
3066 AC_DEFUN([CF_WITH_DMALLOC],[
3067 CF_NO_LEAKS_OPTION(dmalloc,
3068         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
3069         [USE_DMALLOC])
3070
3071 if test "$with_dmalloc" = yes ; then
3072         AC_CHECK_HEADER(dmalloc.h,
3073                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
3074 fi
3075 ])dnl
3076 dnl ---------------------------------------------------------------------------
3077 dnl CF_WITH_NCURSES_ETC version: 2 updated: 2012/01/13 10:49:00
3078 dnl -------------------
3079 dnl Use this macro for programs which use any variant of "curses", e.g.,
3080 dnl "ncurses", and "PDCurses".  Programs that can use curses and some unrelated
3081 dnl library (such as slang) should use a "--with-screen=XXX" option.
3082 dnl
3083 dnl This does not use AC_DEFUN, because that would tell autoconf to run each
3084 dnl of the macros inside this one - before this macro.
3085 define([CF_WITH_NCURSES_ETC],[
3086 CF_WITH_CURSES_DIR
3087
3088 cf_cv_screen=curses
3089
3090 AC_MSG_CHECKING(for specified curses library type)
3091 AC_ARG_WITH(ncursesw,
3092         [  --with-ncursesw         use wide ncurses-libraries],
3093         [cf_cv_screen=ncursesw],[
3094
3095 AC_ARG_WITH(ncurses,
3096         [  --with-ncurses          use ncurses-libraries],
3097         [cf_cv_screen=ncurses],[
3098
3099 AC_ARG_WITH(pdcurses,
3100         [  --with-pdcurses         compile/link with pdcurses X11 library],
3101         [cf_cv_screen=pdcurses],[
3102
3103 AC_ARG_WITH(curses-colr,
3104         [  --with-curses-colr      compile/link with HPUX 10.x color-curses],
3105         [cf_cv_screen=curses_colr],[
3106
3107 AC_ARG_WITH(curses-5lib,
3108         [  --with-curses-5lib      compile/link with SunOS 5lib curses],
3109         [cf_cv_screen=curses_5lib])])])])])
3110
3111 AC_MSG_RESULT($cf_cv_screen)
3112
3113 case $cf_cv_screen in #(vi
3114 curses|curses_*) #(vi
3115         CF_CURSES_CONFIG
3116         ;;
3117 ncurses) #(vi
3118         CF_NCURSES_CONFIG
3119         ;;
3120 ncursesw) #(vi
3121         CF_UTF8_LIB
3122         CF_NCURSES_CONFIG(ncursesw)
3123         ;;
3124 pdcurses)
3125         CF_PDCURSES_X11
3126         ;;
3127 esac
3128
3129 ])dnl
3130 dnl ---------------------------------------------------------------------------
3131 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
3132 dnl ----------------
3133 AC_DEFUN([CF_WITH_VALGRIND],[
3134 CF_NO_LEAKS_OPTION(valgrind,
3135         [  --with-valgrind         test: use valgrind],
3136         [USE_VALGRIND])
3137 ])dnl
3138 dnl ---------------------------------------------------------------------------
3139 dnl CF_XOPEN_CURSES version: 11 updated: 2011/01/18 18:15:30
3140 dnl ---------------
3141 dnl Test if we should define X/Open source for curses, needed on Digital Unix
3142 dnl 4.x, to see the extended functions, but breaks on IRIX 6.x.
3143 dnl
3144 dnl The getbegyx() check is needed for HPUX, which omits legacy macros such
3145 dnl as getbegy().  The latter is better design, but the former is standard.
3146 AC_DEFUN([CF_XOPEN_CURSES],
3147 [
3148 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
3149 AC_CACHE_CHECK(if we must define _XOPEN_SOURCE_EXTENDED,cf_cv_need_xopen_extension,[
3150 AC_TRY_LINK([
3151 #include <stdlib.h>
3152 #include <${cf_cv_ncurses_header:-curses.h}>],[
3153 #if defined(NCURSES_VERSION_PATCH)
3154 #if (NCURSES_VERSION_PATCH < 20100501) && (NCURSES_VERSION_PATCH >= 20100403)
3155         make an error
3156 #endif
3157 #endif
3158         long x = winnstr(stdscr, "", 0);
3159         int x1, y1;
3160         getbegyx(stdscr, y1, x1)],
3161         [cf_cv_need_xopen_extension=no],
3162         [AC_TRY_LINK([
3163 #define _XOPEN_SOURCE_EXTENDED
3164 #include <stdlib.h>
3165 #include <${cf_cv_ncurses_header:-curses.h}>],[
3166 #ifdef NCURSES_VERSION
3167         cchar_t check;
3168         int check2 = curs_set((int)sizeof(check));
3169 #endif
3170         long x = winnstr(stdscr, "", 0);
3171         int x1, y1;
3172         getbegyx(stdscr, y1, x1)],
3173         [cf_cv_need_xopen_extension=yes],
3174         [cf_cv_need_xopen_extension=unknown])])])
3175 test $cf_cv_need_xopen_extension = yes && CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED"
3176 ])dnl
3177 dnl ---------------------------------------------------------------------------
3178 dnl CF_XOPEN_SOURCE version: 46 updated: 2014/02/09 19:30:15
3179 dnl ---------------
3180 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
3181 dnl or adapt to the vendor's definitions to get equivalent functionality,
3182 dnl without losing the common non-POSIX features.
3183 dnl
3184 dnl Parameters:
3185 dnl     $1 is the nominal value for _XOPEN_SOURCE
3186 dnl     $2 is the nominal value for _POSIX_C_SOURCE
3187 AC_DEFUN([CF_XOPEN_SOURCE],[
3188 AC_REQUIRE([AC_CANONICAL_HOST])
3189
3190 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
3191 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
3192 cf_xopen_source=
3193
3194 case $host_os in #(vi
3195 aix[[4-7]]*) #(vi
3196         cf_xopen_source="-D_ALL_SOURCE"
3197         ;;
3198 cygwin|msys) #(vi
3199         cf_XOPEN_SOURCE=600
3200         ;;
3201 darwin[[0-8]].*) #(vi
3202         cf_xopen_source="-D_APPLE_C_SOURCE"
3203         ;;
3204 darwin*) #(vi
3205         cf_xopen_source="-D_DARWIN_C_SOURCE"
3206         cf_XOPEN_SOURCE=
3207         ;;
3208 freebsd*|dragonfly*) #(vi
3209         # 5.x headers associate
3210         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
3211         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
3212         cf_POSIX_C_SOURCE=200112L
3213         cf_XOPEN_SOURCE=600
3214         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3215         ;;
3216 hpux11*) #(vi
3217         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
3218         ;;
3219 hpux*) #(vi
3220         cf_xopen_source="-D_HPUX_SOURCE"
3221         ;;
3222 irix[[56]].*) #(vi
3223         cf_xopen_source="-D_SGI_SOURCE"
3224         cf_XOPEN_SOURCE=
3225         ;;
3226 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
3227         CF_GNU_SOURCE
3228         ;;
3229 mirbsd*) #(vi
3230         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
3231         cf_XOPEN_SOURCE=
3232         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3233         ;;
3234 netbsd*) #(vi
3235         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
3236         ;;
3237 openbsd[[4-9]]*) #(vi
3238         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
3239         cf_xopen_source="-D_BSD_SOURCE"
3240         cf_XOPEN_SOURCE=600
3241         ;;
3242 openbsd*) #(vi
3243         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
3244         ;;
3245 osf[[45]]*) #(vi
3246         cf_xopen_source="-D_OSF_SOURCE"
3247         ;;
3248 nto-qnx*) #(vi
3249         cf_xopen_source="-D_QNX_SOURCE"
3250         ;;
3251 sco*) #(vi
3252         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
3253         ;;
3254 solaris2.*) #(vi
3255         cf_xopen_source="-D__EXTENSIONS__"
3256         cf_cv_xopen_source=broken
3257         ;;
3258 *)
3259         CF_TRY_XOPEN_SOURCE
3260         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3261         ;;
3262 esac
3263
3264 if test -n "$cf_xopen_source" ; then
3265         CF_ADD_CFLAGS($cf_xopen_source)
3266 fi
3267
3268 dnl In anything but the default case, we may have system-specific setting
3269 dnl which is still not guaranteed to provide all of the entrypoints that
3270 dnl _XOPEN_SOURCE would yield.
3271 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
3272         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
3273         AC_TRY_COMPILE([#include <stdlib.h>],[
3274 #ifndef _XOPEN_SOURCE
3275 make an error
3276 #endif],
3277         [cf_XOPEN_SOURCE_set=yes],
3278         [cf_XOPEN_SOURCE_set=no])
3279         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
3280         if test $cf_XOPEN_SOURCE_set = yes
3281         then
3282                 AC_TRY_COMPILE([#include <stdlib.h>],[
3283 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
3284 make an error
3285 #endif],
3286                 [cf_XOPEN_SOURCE_set_ok=yes],
3287                 [cf_XOPEN_SOURCE_set_ok=no])
3288                 if test $cf_XOPEN_SOURCE_set_ok = no
3289                 then
3290                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
3291                 fi
3292         else
3293                 CF_TRY_XOPEN_SOURCE
3294         fi
3295 fi
3296 ])
3297 dnl ---------------------------------------------------------------------------
3298 dnl CF_X_ATHENA version: 21 updated: 2013/07/06 21:27:06
3299 dnl -----------
3300 dnl Check for Xaw (Athena) libraries
3301 dnl
3302 dnl Sets $cf_x_athena according to the flavor of Xaw which is used.
3303 AC_DEFUN([CF_X_ATHENA],
3304 [
3305 cf_x_athena=${cf_x_athena:-Xaw}
3306
3307 AC_MSG_CHECKING(if you want to link with Xaw 3d library)
3308 withval=
3309 AC_ARG_WITH(Xaw3d,
3310         [  --with-Xaw3d            link with Xaw 3d library])
3311 if test "$withval" = yes ; then
3312         cf_x_athena=Xaw3d
3313         AC_MSG_RESULT(yes)
3314 else
3315         AC_MSG_RESULT(no)
3316 fi
3317
3318 AC_MSG_CHECKING(if you want to link with neXT Athena library)
3319 withval=
3320 AC_ARG_WITH(neXtaw,
3321         [  --with-neXtaw           link with neXT Athena library])
3322 if test "$withval" = yes ; then
3323         cf_x_athena=neXtaw
3324         AC_MSG_RESULT(yes)
3325 else
3326         AC_MSG_RESULT(no)
3327 fi
3328
3329 AC_MSG_CHECKING(if you want to link with Athena-Plus library)
3330 withval=
3331 AC_ARG_WITH(XawPlus,
3332         [  --with-XawPlus          link with Athena-Plus library])
3333 if test "$withval" = yes ; then
3334         cf_x_athena=XawPlus
3335         AC_MSG_RESULT(yes)
3336 else
3337         AC_MSG_RESULT(no)
3338 fi
3339
3340 cf_x_athena_lib=""
3341
3342 if test "$PKG_CONFIG" != none ; then
3343         cf_athena_list=
3344         test "$cf_x_athena" = Xaw && cf_athena_list="xaw8 xaw7 xaw6"
3345         for cf_athena_pkg in \
3346                 $cf_athena_list \
3347                 ${cf_x_athena} \
3348                 ${cf_x_athena}-devel \
3349                 lib${cf_x_athena} \
3350                 lib${cf_x_athena}-devel
3351         do
3352                 CF_TRY_PKG_CONFIG($cf_athena_pkg,[
3353                         cf_x_athena_lib="$cf_pkgconfig_libs"
3354                         CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
3355                         AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
3356
3357                         CF_TRIM_X_LIBS
3358
3359 AC_CACHE_CHECK(for usable $cf_x_athena/Xmu package,cf_cv_xaw_compat,[
3360 AC_TRY_LINK([
3361 #include <X11/Xmu/CharSet.h>
3362 ],[
3363 int check = XmuCompareISOLatin1("big", "small")
3364 ],[cf_cv_xaw_compat=yes],[cf_cv_xaw_compat=no])])
3365
3366                         if test "$cf_cv_xaw_compat" = no
3367                         then
3368                                 # workaround for broken ".pc" files...
3369                                 case "$cf_x_athena_lib" in #(vi
3370                                 *-lXmu*) #(vi
3371                                         ;;
3372                                 *)
3373                                         CF_VERBOSE(work around broken package)
3374                                         cf_save_xmu="$LIBS"
3375                                         cf_first_lib=`echo "$cf_save_xmu" | sed -e 's/^[ ][ ]*//' -e 's/ .*//'`
3376                                         CF_TRY_PKG_CONFIG(xmu,[
3377                                                         LIBS="$cf_save_xmu"
3378                                                         CF_ADD_LIB_AFTER($cf_first_lib,$cf_pkgconfig_libs)
3379                                                 ],[
3380                                                         CF_ADD_LIB_AFTER($cf_first_lib,-lXmu)
3381                                                 ])
3382                                         CF_TRIM_X_LIBS
3383                                         ;;
3384                                 esac
3385                         fi
3386
3387                         break])
3388         done
3389 fi
3390
3391 if test -z "$cf_x_athena_lib" ; then
3392         CF_X_EXT
3393         CF_X_TOOLKIT
3394         CF_X_ATHENA_CPPFLAGS($cf_x_athena)
3395         CF_X_ATHENA_LIBS($cf_x_athena)
3396 fi
3397 ])dnl
3398 dnl ---------------------------------------------------------------------------
3399 dnl CF_X_ATHENA_CPPFLAGS version: 5 updated: 2010/05/26 17:35:30
3400 dnl --------------------
3401 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
3402 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
3403 AC_DEFUN([CF_X_ATHENA_CPPFLAGS],
3404 [
3405 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
3406 cf_x_athena_inc=""
3407
3408 for cf_path in default \
3409         /usr/contrib/X11R6 \
3410         /usr/contrib/X11R5 \
3411         /usr/lib/X11R5 \
3412         /usr/local
3413 do
3414         if test -z "$cf_x_athena_inc" ; then
3415                 cf_save="$CPPFLAGS"
3416                 cf_test=X11/$cf_x_athena_root/SimpleMenu.h
3417                 if test $cf_path != default ; then
3418                         CPPFLAGS="$cf_save -I$cf_path/include"
3419                         AC_MSG_CHECKING(for $cf_test in $cf_path)
3420                 else
3421                         AC_MSG_CHECKING(for $cf_test)
3422                 fi
3423                 AC_TRY_COMPILE([
3424 #include <X11/Intrinsic.h>
3425 #include <$cf_test>],[],
3426                         [cf_result=yes],
3427                         [cf_result=no])
3428                 AC_MSG_RESULT($cf_result)
3429                 if test "$cf_result" = yes ; then
3430                         cf_x_athena_inc=$cf_path
3431                         break
3432                 else
3433                         CPPFLAGS="$cf_save"
3434                 fi
3435         fi
3436 done
3437
3438 if test -z "$cf_x_athena_inc" ; then
3439         AC_MSG_WARN(
3440 [Unable to successfully find Athena header files with test program])
3441 elif test "$cf_x_athena_inc" != default ; then
3442         CPPFLAGS="$CPPFLAGS -I$cf_x_athena_inc"
3443 fi
3444 ])
3445 dnl ---------------------------------------------------------------------------
3446 dnl CF_X_ATHENA_LIBS version: 12 updated: 2011/07/17 19:55:02
3447 dnl ----------------
3448 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
3449 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
3450 AC_DEFUN([CF_X_ATHENA_LIBS],
3451 [AC_REQUIRE([CF_X_TOOLKIT])
3452 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
3453 cf_x_athena_lib=""
3454
3455 for cf_path in default \
3456         /usr/contrib/X11R6 \
3457         /usr/contrib/X11R5 \
3458         /usr/lib/X11R5 \
3459         /usr/local
3460 do
3461         for cf_lib in \
3462                 ${cf_x_athena_root} \
3463                 ${cf_x_athena_root}7 \
3464                 ${cf_x_athena_root}6
3465         do
3466         for cf_libs in \
3467                 "-l$cf_lib -lXmu" \
3468                 "-l$cf_lib -lXpm -lXmu" \
3469                 "-l${cf_lib}_s -lXmu_s"
3470         do
3471                 if test -z "$cf_x_athena_lib" ; then
3472                         cf_save="$LIBS"
3473                         cf_test=XawSimpleMenuAddGlobalActions
3474                         if test $cf_path != default ; then
3475                                 CF_ADD_LIBS(-L$cf_path/lib $cf_libs)
3476                                 AC_MSG_CHECKING(for $cf_libs in $cf_path)
3477                         else
3478                                 CF_ADD_LIBS($cf_libs)
3479                                 AC_MSG_CHECKING(for $cf_test in $cf_libs)
3480                         fi
3481                         AC_TRY_LINK([
3482 #include <X11/Intrinsic.h>
3483 #include <X11/$cf_x_athena_root/SimpleMenu.h>
3484 ],[
3485 $cf_test((XtAppContext) 0)],
3486                                 [cf_result=yes],
3487                                 [cf_result=no])
3488                         AC_MSG_RESULT($cf_result)
3489                         if test "$cf_result" = yes ; then
3490                                 cf_x_athena_lib="$cf_libs"
3491                                 break
3492                         fi
3493                         LIBS="$cf_save"
3494                 fi
3495         done # cf_libs
3496                 test -n "$cf_x_athena_lib" && break
3497         done # cf_lib
3498 done
3499
3500 if test -z "$cf_x_athena_lib" ; then
3501         AC_MSG_ERROR(
3502 [Unable to successfully link Athena library (-l$cf_x_athena_root) with test program])
3503 fi
3504
3505 CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
3506 AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
3507 ])
3508 dnl ---------------------------------------------------------------------------
3509 dnl CF_X_EXT version: 3 updated: 2010/06/02 05:03:05
3510 dnl --------
3511 AC_DEFUN([CF_X_EXT],[
3512 CF_TRY_PKG_CONFIG(Xext,,[
3513         AC_CHECK_LIB(Xext,XextCreateExtension,
3514                 [CF_ADD_LIB(Xext)])])
3515 ])dnl
3516 dnl ---------------------------------------------------------------------------
3517 dnl CF_X_TOOLKIT version: 21 updated: 2012/10/04 06:57:36
3518 dnl ------------
3519 dnl Check for X Toolkit libraries
3520 dnl
3521 AC_DEFUN([CF_X_TOOLKIT],
3522 [
3523 AC_REQUIRE([AC_PATH_XTRA])
3524 AC_REQUIRE([CF_CHECK_CACHE])
3525
3526 cf_have_X_LIBS=no
3527
3528 CF_TRY_PKG_CONFIG(xt,[
3529
3530         case "x$LIBS" in #(vi
3531         *-lX11*) #(vi
3532                 ;;
3533         *)
3534 # we have an "xt" package, but it may omit Xt's dependency on X11
3535 AC_CACHE_CHECK(for usable X dependency,cf_cv_xt_x11_compat,[
3536 AC_TRY_LINK([
3537 #include <X11/Xlib.h>
3538 ],[
3539         int rc1 = XDrawLine((Display*) 0, (Drawable) 0, (GC) 0, 0, 0, 0, 0);
3540         int rc2 = XClearWindow((Display*) 0, (Window) 0);
3541         int rc3 = XMoveWindow((Display*) 0, (Window) 0, 0, 0);
3542         int rc4 = XMoveResizeWindow((Display*)0, (Window)0, 0, 0, 0, 0);
3543 ],[cf_cv_xt_x11_compat=yes],[cf_cv_xt_x11_compat=no])])
3544                 if test "$cf_cv_xt_x11_compat" = no
3545                 then
3546                         CF_VERBOSE(work around broken X11 dependency)
3547                         # 2010/11/19 - good enough until a working Xt on Xcb is delivered.
3548                         CF_TRY_PKG_CONFIG(x11,,[CF_ADD_LIB_AFTER(-lXt,-lX11)])
3549                 fi
3550                 ;;
3551         esac
3552
3553 AC_CACHE_CHECK(for usable X Toolkit package,cf_cv_xt_ice_compat,[
3554 AC_TRY_LINK([
3555 #include <X11/Shell.h>
3556 ],[int num = IceConnectionNumber(0)
3557 ],[cf_cv_xt_ice_compat=yes],[cf_cv_xt_ice_compat=no])])
3558
3559         if test "$cf_cv_xt_ice_compat" = no
3560         then
3561                 # workaround for broken ".pc" files used for X Toolkit.
3562                 case "x$X_PRE_LIBS" in #(vi
3563                 *-lICE*)
3564                         case "x$LIBS" in #(vi
3565                         *-lICE*) #(vi
3566                                 ;;
3567                         *)
3568                                 CF_VERBOSE(work around broken ICE dependency)
3569                                 CF_TRY_PKG_CONFIG(ice,
3570                                         [CF_TRY_PKG_CONFIG(sm)],
3571                                         [CF_ADD_LIB_AFTER(-lXt,$X_PRE_LIBS)])
3572                                 ;;
3573                         esac
3574                         ;;
3575                 esac
3576         fi
3577
3578         cf_have_X_LIBS=yes
3579 ],[
3580
3581         LDFLAGS="$X_LIBS $LDFLAGS"
3582         CF_CHECK_CFLAGS($X_CFLAGS)
3583
3584         AC_CHECK_FUNC(XOpenDisplay,,[
3585         AC_CHECK_LIB(X11,XOpenDisplay,
3586                 [CF_ADD_LIB(X11)],,
3587                 [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])])
3588
3589         AC_CHECK_FUNC(XtAppInitialize,,[
3590         AC_CHECK_LIB(Xt, XtAppInitialize,
3591                 [AC_DEFINE(HAVE_LIBXT,1,[Define to 1 if we can compile with the Xt library])
3592                  cf_have_X_LIBS=Xt
3593                  LIBS="-lXt $X_PRE_LIBS $LIBS $X_EXTRA_LIBS"],,
3594                 [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])])
3595 ])
3596
3597 if test $cf_have_X_LIBS = no ; then
3598         AC_MSG_WARN(
3599 [Unable to successfully link X Toolkit library (-lXt) with
3600 test program.  You will have to check and add the proper libraries by hand
3601 to makefile.])
3602 fi
3603 ])dnl
3604 dnl ---------------------------------------------------------------------------
3605 dnl CF__CURSES_HEAD version: 2 updated: 2010/10/23 15:54:49
3606 dnl ---------------
3607 dnl Define a reusable chunk which includes <curses.h> and <term.h> when they
3608 dnl are both available.
3609 define([CF__CURSES_HEAD],[
3610 #ifdef HAVE_XCURSES
3611 #include <xcurses.h>
3612 char * XCursesProgramName = "test";
3613 #else
3614 #include <${cf_cv_ncurses_header:-curses.h}>
3615 #if defined(NCURSES_VERSION) && defined(HAVE_NCURSESW_TERM_H)
3616 #include <ncursesw/term.h>
3617 #elif defined(NCURSES_VERSION) && defined(HAVE_NCURSES_TERM_H)
3618 #include <ncurses/term.h>
3619 #elif defined(HAVE_TERM_H)
3620 #include <term.h>
3621 #endif
3622 #endif
3623 ])