test/aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2023,2024 Thomas E. Dickey                                *
   3 dnl Copyright 2003-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl $Id: aclocal.m4,v 1.221 2024/01/19 18:27:20 tom Exp $
  31 dnl
  32 dnl Author: Thomas E. Dickey
  33 dnl
  34 dnl Macros used in NCURSES test programs auto-configuration script.
  35 dnl
  36 dnl These macros are maintained separately from NCURSES.  The copyright on
  37 dnl this file applies to the aggregation of macros and does not affect use of
  38 dnl these macros in other applications.
  39 dnl
  40 dnl See these pages for additional information:
  41 dnl             https://invisible-island.net/autoconf/
  42 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  43 dnl
  44 dnl ---------------------------------------------------------------------------
  45 dnl ---------------------------------------------------------------------------
  46 dnl AM_LANGINFO_CODESET version: 7 updated: 2023/01/11 04:05:23
  47 dnl -------------------
  48 dnl Inserted as requested by gettext 0.10.40
  49 dnl File from /usr/share/aclocal
  50 dnl codeset.m4
  51 dnl ====================
  52 dnl serial AM1
  53 dnl
  54 dnl From Bruno Haible.
  55 AC_DEFUN([AM_LANGINFO_CODESET],
  56 [
  57 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  58         [AC_TRY_LINK([
  59 $ac_includes_default
  60 #include <langinfo.h>],
  61         [char* cs = nl_langinfo(CODESET); (void)cs],
  62         am_cv_langinfo_codeset=yes,
  63         am_cv_langinfo_codeset=no)
  64         ])
  65         if test "$am_cv_langinfo_codeset" = yes; then
  66                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  67                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  68         fi
  69 ])dnl
  70 dnl ---------------------------------------------------------------------------
  71 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
  72 dnl ------------------
  73 dnl Conditionally generate script according to whether we're using a given autoconf.
  74 dnl
  75 dnl $1 = version to compare against
  76 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  77 dnl $3 = code to use if AC_ACVERSION is older than $1.
  78 define([CF_ACVERSION_CHECK],
  79 [
  80 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
  81 ifdef([m4_version_compare],
  82 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  83 [CF_ACVERSION_COMPARE(
  84 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  85 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  86 dnl ---------------------------------------------------------------------------
  87 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  88 dnl --------------------
  89 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  90 dnl                      MAJOR2, MINOR2, TERNARY2,
  91 dnl                      PRINTABLE2, not FOUND, FOUND)
  92 define([CF_ACVERSION_COMPARE],
  93 [ifelse(builtin([eval], [$2 < $5]), 1,
  94 [ifelse([$8], , ,[$8])],
  95 [ifelse([$9], , ,[$9])])])dnl
  96 dnl ---------------------------------------------------------------------------
  97 dnl CF_ADD_CFLAGS version: 15 updated: 2020/12/31 10:54:15
  98 dnl -------------
  99 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 100 dnl $1 = flags to add
 101 dnl $2 = if given makes this macro verbose.
 102 dnl
 103 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 104 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 105 dnl confused by the quotes (which require backslashes to keep them usable).
 106 AC_DEFUN([CF_ADD_CFLAGS],
 107 [
 108 cf_fix_cppflags=no
 109 cf_new_cflags=
 110 cf_new_cppflags=
 111 cf_new_extra_cppflags=
 112
 113 for cf_add_cflags in $1
 114 do
 115 case "$cf_fix_cppflags" in
 116 (no)
 117         case "$cf_add_cflags" in
 118         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 119                 case "$cf_add_cflags" in
 120                 (-D*)
 121                         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 122
 123                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 124                                 && test -z "${cf_tst_cflags}" \
 125                                 && cf_fix_cppflags=yes
 126
 127                         if test "$cf_fix_cppflags" = yes ; then
 128                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 129                                 continue
 130                         elif test "${cf_tst_cflags}" = "\"'" ; then
 131                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 132                                 continue
 133                         fi
 134                         ;;
 135                 esac
 136                 case "$CPPFLAGS" in
 137                 (*$cf_add_cflags)
 138                         ;;
 139                 (*)
 140                         case "$cf_add_cflags" in
 141                         (-D*)
 142                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 143                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 144                                 ;;
 145                         esac
 146                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 147                         ;;
 148                 esac
 149                 ;;
 150         (*)
 151                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 152                 ;;
 153         esac
 154         ;;
 155 (yes)
 156         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 157
 158         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^[[^"]]*"'\''//'`
 159
 160         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 161                 && test -z "${cf_tst_cflags}" \
 162                 && cf_fix_cppflags=no
 163         ;;
 164 esac
 165 done
 166
 167 if test -n "$cf_new_cflags" ; then
 168         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 169         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 170 fi
 171
 172 if test -n "$cf_new_cppflags" ; then
 173         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 174         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 175 fi
 176
 177 if test -n "$cf_new_extra_cppflags" ; then
 178         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 179         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 180 fi
 181
 182 AC_SUBST(EXTRA_CPPFLAGS)
 183
 184 ])dnl
 185 dnl ---------------------------------------------------------------------------
 186 dnl CF_ADD_INCDIR version: 17 updated: 2021/09/04 06:35:04
 187 dnl -------------
 188 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it is
 189 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 190 dnl but old versions (and some misinstalled ones) need that.  To make things
 191 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 192 dnl the include-path).
 193 AC_DEFUN([CF_ADD_INCDIR],
 194 [
 195 if test -n "$1" ; then
 196   for cf_add_incdir in $1
 197   do
 198         while test "$cf_add_incdir" != /usr/include
 199         do
 200           if test -d "$cf_add_incdir"
 201           then
 202                 cf_have_incdir=no
 203                 if test -n "$CFLAGS$CPPFLAGS" ; then
 204                   # a loop is needed to ensure we can add subdirs of existing dirs
 205                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 206                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 207                           cf_have_incdir=yes; break
 208                         fi
 209                   done
 210                 fi
 211
 212                 if test "$cf_have_incdir" = no ; then
 213                   if test "$cf_add_incdir" = /usr/local/include ; then
 214                         if test "$GCC" = yes
 215                         then
 216                           cf_save_CPPFLAGS=$CPPFLAGS
 217                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 218                           AC_TRY_COMPILE([#include <stdio.h>],
 219                                   [printf("Hello")],
 220                                   [],
 221                                   [cf_have_incdir=yes])
 222                           CPPFLAGS=$cf_save_CPPFLAGS
 223                         fi
 224                   fi
 225                 fi
 226
 227                 if test "$cf_have_incdir" = no ; then
 228                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 229                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 230
 231                   cf_top_incdir=`echo "$cf_add_incdir" | sed -e 's%/include/.*$%/include%'`
 232                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 233                   cf_add_incdir="$cf_top_incdir"
 234                 else
 235                   break
 236                 fi
 237           else
 238                 break
 239           fi
 240         done
 241   done
 242 fi
 243 ])dnl
 244 dnl ---------------------------------------------------------------------------
 245 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 246 dnl ----------
 247 dnl Add a library, used to enforce consistency.
 248 dnl
 249 dnl $1 = library to add, without the "-l"
 250 dnl $2 = variable to update (default $LIBS)
 251 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 252 dnl ---------------------------------------------------------------------------
 253 dnl CF_ADD_LIBDIR version: 11 updated: 2020/12/31 20:19:42
 254 dnl -------------
 255 dnl     Adds to the library-path
 256 dnl
 257 dnl     Some machines have trouble with multiple -L options.
 258 dnl
 259 dnl $1 is the (list of) directory(s) to add
 260 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 261 dnl
 262 AC_DEFUN([CF_ADD_LIBDIR],
 263 [
 264 if test -n "$1" ; then
 265         for cf_add_libdir in $1
 266         do
 267                 if test "$cf_add_libdir" = /usr/lib ; then
 268                         :
 269                 elif test -d "$cf_add_libdir"
 270                 then
 271                         cf_have_libdir=no
 272                         if test -n "$LDFLAGS$LIBS" ; then
 273                                 # a loop is needed to ensure we can add subdirs of existing dirs
 274                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 275                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 276                                                 cf_have_libdir=yes; break
 277                                         fi
 278                                 done
 279                         fi
 280                         if test "$cf_have_libdir" = no ; then
 281                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 282                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 283                         fi
 284                 fi
 285         done
 286 fi
 287 ])dnl
 288 dnl ---------------------------------------------------------------------------
 289 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
 290 dnl -----------
 291 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 292 dnl prepended to an existing list, since their dependencies are assumed to
 293 dnl already exist in the list.
 294 dnl
 295 dnl $1 = libraries to add, with the "-l", etc.
 296 dnl $2 = variable to update (default $LIBS)
 297 AC_DEFUN([CF_ADD_LIBS],[
 298 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
 299 # reverse order
 300 cf_add_0lib=
 301 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
 302 # filter duplicates
 303 for cf_add_1lib in $cf_add_0lib; do
 304         for cf_add_2lib in $cf_add_libs; do
 305                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
 306                         cf_add_1lib=
 307                         break
 308                 fi
 309         done
 310         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
 311 done
 312 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 313 ])dnl
 314 dnl ---------------------------------------------------------------------------
 315 dnl CF_ADD_LIB_AFTER version: 3 updated: 2013/07/09 21:27:22
 316 dnl ----------------
 317 dnl Add a given library after another, e.g., following the one it satisfies a
 318 dnl dependency for.
 319 dnl
 320 dnl $1 = the first library
 321 dnl $2 = its dependency
 322 AC_DEFUN([CF_ADD_LIB_AFTER],[
 323 CF_VERBOSE(...before $LIBS)
 324 LIBS=`echo "$LIBS" | sed -e "s/[[       ]][[    ]]*/ /g" -e "s%$1 %$1 $2 %" -e 's%  % %g'`
 325 CF_VERBOSE(...after  $LIBS)
 326 ])dnl
 327 dnl ---------------------------------------------------------------------------
 328 dnl CF_ADD_SUBDIR_PATH version: 5 updated: 2020/12/31 20:19:42
 329 dnl ------------------
 330 dnl Append to a search-list for a nonstandard header/lib-file
 331 dnl     $1 = the variable to return as result
 332 dnl     $2 = the package name
 333 dnl     $3 = the subdirectory, e.g., bin, include or lib
 334 dnl $4 = the directory under which we will test for subdirectories
 335 dnl $5 = a directory that we do not want $4 to match
 336 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 337 [
 338 test "x$4" != "x$5" && \
 339 test -d "$4" && \
 340 ifelse([$5],NONE,,[{ test -z "$5" || test "x$5" = xNONE || test "x$4" != "x$5"; } &&]) {
 341         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 342         test -d "$4/$3" &&          $1="[$]$1 $4/$3"
 343         test -d "$4/$3/$2" &&       $1="[$]$1 $4/$3/$2"
 344         test -d "$4/$3/$2/$3" &&    $1="[$]$1 $4/$3/$2/$3"
 345         test -d "$4/$2/$3" &&       $1="[$]$1 $4/$2/$3"
 346         test -d "$4/$2/$3/$2" &&    $1="[$]$1 $4/$2/$3/$2"
 347 }
 348 ])dnl
 349 dnl ---------------------------------------------------------------------------
 350 dnl CF_APPEND_CFLAGS version: 3 updated: 2021/09/05 17:25:40
 351 dnl ----------------
 352 dnl Use CF_ADD_CFLAGS after first checking for potential redefinitions.
 353 dnl $1 = flags to add
 354 dnl $2 = if given makes this macro verbose.
 355 define([CF_APPEND_CFLAGS],
 356 [
 357 for cf_add_cflags in $1
 358 do
 359         case "x$cf_add_cflags" in
 360         (x-[[DU]]*)
 361                 CF_REMOVE_CFLAGS($cf_add_cflags,CFLAGS,[$2])
 362                 CF_REMOVE_CFLAGS($cf_add_cflags,CPPFLAGS,[$2])
 363                 ;;
 364         esac
 365         CF_ADD_CFLAGS([$cf_add_cflags],[$2])
 366 done
 367 ])dnl
 368 dnl ---------------------------------------------------------------------------
 369 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 370 dnl --------------
 371 dnl use this macro for appending text without introducing an extra blank at
 372 dnl the beginning
 373 define([CF_APPEND_TEXT],
 374 [
 375         test -n "[$]$1" && $1="[$]$1 "
 376         $1="[$]{$1}$2"
 377 ])dnl
 378 dnl ---------------------------------------------------------------------------
 379 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 380 dnl --------------
 381 dnl Allow user to disable a normally-on option.
 382 AC_DEFUN([CF_ARG_DISABLE],
 383 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 384 dnl ---------------------------------------------------------------------------
 385 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 386 dnl -------------
 387 dnl Allow user to enable a normally-off option.
 388 AC_DEFUN([CF_ARG_ENABLE],
 389 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 390 dnl ---------------------------------------------------------------------------
 391 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 392 dnl -------------
 393 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 394 dnl values.
 395 dnl
 396 dnl Parameters:
 397 dnl $1 = option name
 398 dnl $2 = help-string
 399 dnl $3 = action to perform if option is not default
 400 dnl $4 = action if perform if option is default
 401 dnl $5 = default option value (either 'yes' or 'no')
 402 AC_DEFUN([CF_ARG_OPTION],
 403 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 404         if test "$enableval" != "$5" ; then
 405 ifelse([$3],,[    :]dnl
 406 ,[    $3]) ifelse([$4],,,[
 407         else
 408                 $4])
 409         fi],[enableval=$5 ifelse([$4],,,[
 410         $4
 411 ])dnl
 412 ])])dnl
 413 dnl ---------------------------------------------------------------------------
 414 dnl CF_C11_NORETURN version: 4 updated: 2023/02/18 17:41:25
 415 dnl ---------------
 416 AC_DEFUN([CF_C11_NORETURN],
 417 [
 418 AC_MSG_CHECKING(if you want to use C11 _Noreturn feature)
 419 CF_ARG_ENABLE(stdnoreturn,
 420         [  --enable-stdnoreturn    enable C11 _Noreturn feature for diagnostics],
 421         [enable_stdnoreturn=yes],
 422         [enable_stdnoreturn=no])
 423 AC_MSG_RESULT($enable_stdnoreturn)
 424
 425 if test $enable_stdnoreturn = yes; then
 426 AC_CACHE_CHECK([for C11 _Noreturn feature], cf_cv_c11_noreturn,
 427         [AC_TRY_COMPILE([
 428 $ac_includes_default
 429 #include <stdnoreturn.h>
 430 static _Noreturn void giveup(void) { exit(0); }
 431         ],
 432         [if (feof(stdin)) giveup()],
 433         cf_cv_c11_noreturn=yes,
 434         cf_cv_c11_noreturn=no)
 435         ])
 436 else
 437         cf_cv_c11_noreturn=no,
 438 fi
 439
 440 if test "$cf_cv_c11_noreturn" = yes; then
 441         AC_DEFINE(HAVE_STDNORETURN_H, 1,[Define if <stdnoreturn.h> header is available and working])
 442         AC_DEFINE_UNQUOTED(STDC_NORETURN,_Noreturn,[Define if C11 _Noreturn keyword is supported])
 443         HAVE_STDNORETURN_H=1
 444 else
 445         HAVE_STDNORETURN_H=0
 446 fi
 447
 448 AC_SUBST(HAVE_STDNORETURN_H)
 449 AC_SUBST(STDC_NORETURN)
 450 ])dnl
 451 dnl ---------------------------------------------------------------------------
 452 dnl CF_CC_ENV_FLAGS version: 11 updated: 2023/02/20 11:15:46
 453 dnl ---------------
 454 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 455 dnl into CC.  This will not help with broken scripts that wrap the compiler
 456 dnl with options, but eliminates a more common category of user confusion.
 457 dnl
 458 dnl In particular, it addresses the problem of being able to run the C
 459 dnl preprocessor in a consistent manner.
 460 dnl
 461 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 462 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 463 dnl outweighs that limitation.
 464 AC_DEFUN([CF_CC_ENV_FLAGS],
 465 [
 466 # This should have been defined by AC_PROG_CC
 467 : "${CC:=cc}"
 468
 469 AC_MSG_CHECKING(\$CFLAGS variable)
 470 case "x$CFLAGS" in
 471 (*-[[IUD]]*)
 472         AC_MSG_RESULT(broken)
 473         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 474         cf_flags="$CFLAGS"
 475         CFLAGS=
 476         for cf_arg in $cf_flags
 477         do
 478                 CF_ADD_CFLAGS($cf_arg)
 479         done
 480         ;;
 481 (*)
 482         AC_MSG_RESULT(ok)
 483         ;;
 484 esac
 485
 486 AC_MSG_CHECKING(\$CC variable)
 487 case "$CC" in
 488 (*[[\ \ ]]-*)
 489         AC_MSG_RESULT(broken)
 490         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 491         # humor him...
 492         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 493         cf_flags=`echo "$CC" | sed -e "s%^$cf_prog%%"`
 494         CC="$cf_prog"
 495         for cf_arg in $cf_flags
 496         do
 497                 case "x$cf_arg" in
 498                 (x-[[IUDfgOW]]*)
 499                         CF_ADD_CFLAGS($cf_arg)
 500                         ;;
 501                 (*)
 502                         CC="$CC $cf_arg"
 503                         ;;
 504                 esac
 505         done
 506         CF_VERBOSE(resulting CC: '$CC')
 507         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 508         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 509         ;;
 510 (*)
 511         AC_MSG_RESULT(ok)
 512         ;;
 513 esac
 514 ])dnl
 515 dnl ---------------------------------------------------------------------------
 516 dnl CF_CHECK_CACHE version: 13 updated: 2020/12/31 10:54:15
 517 dnl --------------
 518 dnl Check if we're accidentally using a cache from a different machine.
 519 dnl Derive the system name, as a check for reusing the autoconf cache.
 520 dnl
 521 dnl If we've packaged config.guess and config.sub, run that (since it does a
 522 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 523 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 524 dnl which is useful in cross-compiles.
 525 dnl
 526 dnl Note: we would use $ac_config_sub, but that is one of the places where
 527 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 528 AC_DEFUN([CF_CHECK_CACHE],
 529 [
 530 if test -f "$srcdir/config.guess" || test -f "$ac_aux_dir/config.guess" ; then
 531         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 532         system_name="$host_os"
 533 else
 534         system_name="`(uname -s -r) 2>/dev/null`"
 535         if test -z "$system_name" ; then
 536                 system_name="`(hostname) 2>/dev/null`"
 537         fi
 538 fi
 539 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 540 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 541
 542 test -z "$system_name" && system_name="$cf_cv_system_name"
 543 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 544
 545 if test ".$system_name" != ".$cf_cv_system_name" ; then
 546         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 547         AC_MSG_ERROR("Please remove config.cache and try again.")
 548 fi
 549 ])dnl
 550 dnl ---------------------------------------------------------------------------
 551 dnl CF_CHECK_CFLAGS version: 4 updated: 2021/01/02 19:22:58
 552 dnl ---------------
 553 dnl Conditionally add to $CFLAGS and $CPPFLAGS values which are derived from
 554 dnl a build-configuration such as imake.  These have the pitfall that they
 555 dnl often contain compiler-specific options which we cannot use, mixed with
 556 dnl preprocessor options that we usually can.
 557 AC_DEFUN([CF_CHECK_CFLAGS],
 558 [
 559 CF_VERBOSE(checking additions to CFLAGS)
 560 cf_check_cflags="$CFLAGS"
 561 cf_check_cppflags="$CPPFLAGS"
 562 CF_ADD_CFLAGS($1,yes)
 563 if test "x$cf_check_cflags" != "x$CFLAGS" ; then
 564 AC_TRY_LINK([#include <stdio.h>],[printf("Hello world");],,
 565         [CF_VERBOSE(test-compile failed.  Undoing change to \$CFLAGS)
 566          if test "x$cf_check_cppflags" != "x$CPPFLAGS" ; then
 567                  CF_VERBOSE(but keeping change to \$CPPFLAGS)
 568          fi
 569          CFLAGS="$cf_check_cflags"])
 570 fi
 571 ])dnl
 572 dnl ---------------------------------------------------------------------------
 573 dnl CF_CHECK_CURSES_LIB version: 4 updated: 2021/09/05 17:25:40
 574 dnl -------------------
 575 dnl $1 = nominal library name, used also for header lookup
 576 dnl $2 = suffix to append to library name
 577 dnl $3 = function to check for using AC_CHECK_LIB
 578 dnl $4 = optional parameter list for $3
 579 AC_DEFUN([CF_CHECK_CURSES_LIB],
 580 [
 581 AC_REQUIRE([CF_PKG_CONFIG])
 582
 583 cf_have_curses_lib=no
 584
 585 : ${NCURSES_CONFIG_PKG:=none}
 586 if test "x${NCURSES_CONFIG_PKG}" = xnone; then
 587         :
 588 elif test "x${PKG_CONFIG:=none}" != xnone; then
 589         AC_MSG_CHECKING(pkg-config for $1$2)
 590         if "$PKG_CONFIG" --exists "$1$2" ; then
 591                 AC_MSG_RESULT(yes)
 592
 593                 AC_MSG_CHECKING(if the $1$2 package files work)
 594
 595                 cf_save_CFLAGS="$CFLAGS"
 596                 cf_save_CPPFLAGS="$CPPFLAGS"
 597                 cf_save_LIBS="$LIBS"
 598
 599                 CF_APPEND_CFLAGS(`$PKG_CONFIG --cflags "$1$2"`)
 600                 CF_ADD_LIBS(`$PKG_CONFIG --libs "$1$2"`)
 601
 602                 AC_TRY_LINK([#include <$1.h>],
 603                         [(void) $3 ( ]ifelse([$4],,,[[$4]])[ );],
 604                         [AC_TRY_RUN([#include <$1.h>
 605                                 int main(void)
 606                                 { (void) $3 ( ]ifelse([$4],,,[[$4]])[ ); return 0; }],
 607                                 [cf_have_curses_lib=yes],
 608                                 [cf_have_curses_lib=no],
 609                                 [cf_have_curses_lib=maybe])],
 610                         [cf_have_curses_lib=no])
 611                 AC_MSG_RESULT($cf_have_curses_lib)
 612                 test "$cf_have_curses_lib" = maybe && cf_have_curses_lib=yes
 613                 if test "$cf_have_curses_lib" = "yes"
 614                 then
 615                         CF_UPPER(cf_upper,have_lib$1)
 616                         AC_DEFINE_UNQUOTED($cf_upper,1)
 617                 else
 618                         CFLAGS="$cf_save_CFLAGS"
 619                         CPPFLAGS="$cf_save_CPPFLAGS"
 620                         LIBS="$cf_save_LIBS"
 621                 fi
 622         fi
 623 fi
 624 if test "$cf_have_curses_lib" = no; then
 625         AC_CHECK_LIB($1$2,$3,[
 626                 CF_UPPER(cf_upper,have_lib$1)
 627                 CF_ADD_LIBS(-l$1$2)
 628                 AC_DEFINE_UNQUOTED($cf_upper,1)])
 629 fi
 630 ])dnl
 631 dnl ---------------------------------------------------------------------------
 632 dnl CF_CLANG_COMPILER version: 9 updated: 2023/02/18 17:41:25
 633 dnl -----------------
 634 dnl Check if the given compiler is really clang.  clang's C driver defines
 635 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 636 dnl not ignore some gcc options.
 637 dnl
 638 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 639 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 640 dnl the wrappers for gcc and g++ warnings.
 641 dnl
 642 dnl $1 = GCC (default) or GXX
 643 dnl $2 = CLANG_COMPILER (default)
 644 dnl $3 = CFLAGS (default) or CXXFLAGS
 645 AC_DEFUN([CF_CLANG_COMPILER],[
 646 ifelse([$2],,CLANG_COMPILER,[$2])=no
 647
 648 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 649         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 650         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 651         AC_TRY_COMPILE([],[
 652 #ifdef __clang__
 653 #else
 654 #error __clang__ is not defined
 655 #endif
 656 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 657 ],[])
 658         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 659         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 660 fi
 661
 662 CLANG_VERSION=none
 663
 664 if test "x$ifelse([$2],,CLANG_COMPILER,[$2])" = "xyes" ; then
 665         case "$CC" in
 666         (c[[1-9]][[0-9]]|*/c[[1-9]][[0-9]])
 667                 AC_MSG_WARN(replacing broken compiler alias $CC)
 668                 CFLAGS="$CFLAGS -std=`echo "$CC" | sed -e 's%.*/%%'`"
 669                 CC=clang
 670                 ;;
 671         esac
 672
 673         AC_MSG_CHECKING(version of $CC)
 674         CLANG_VERSION="`$CC --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(CLANG[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
 675         test -z "$CLANG_VERSION" && CLANG_VERSION=unknown
 676         AC_MSG_RESULT($CLANG_VERSION)
 677
 678         for cf_clang_opt in \
 679                 -Qunused-arguments \
 680                 -Wno-error=implicit-function-declaration
 681         do
 682                 AC_MSG_CHECKING(if option $cf_clang_opt works)
 683                 cf_save_CFLAGS="$CFLAGS"
 684                 CFLAGS="$CFLAGS $cf_clang_opt"
 685                 AC_TRY_LINK([
 686                         #include <stdio.h>],[
 687                         printf("hello!\\n");],[
 688                         cf_clang_optok=yes],[
 689                         cf_clang_optok=no])
 690                 AC_MSG_RESULT($cf_clang_optok)
 691                 CFLAGS="$cf_save_CFLAGS"
 692                 if test "$cf_clang_optok" = yes; then
 693                         CF_VERBOSE(adding option $cf_clang_opt)
 694                         CF_APPEND_TEXT(CFLAGS,$cf_clang_opt)
 695                 fi
 696         done
 697 fi
 698 ])
 699 dnl ---------------------------------------------------------------------------
 700 dnl CF_CONST_X_STRING version: 8 updated: 2023/12/01 17:22:50
 701 dnl -----------------
 702 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
 703 dnl character-strings.
 704 dnl
 705 dnl It is ambiguous because the specification accommodated the pre-ANSI
 706 dnl compilers bundled by more than one vendor in lieu of providing a standard C
 707 dnl compiler other than by costly add-ons.  Because of this, the specification
 708 dnl did not take into account the use of const for telling the compiler that
 709 dnl string literals would be in readonly memory.
 710 dnl
 711 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
 712 dnl let the compiler decide how to represent Xt's strings which were #define'd.
 713 dnl That does not solve the problem of using the block of Xt's strings which
 714 dnl are compiled into the library (and is less efficient than one might want).
 715 dnl
 716 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
 717 dnl when compiling the library and compiling using the library, to tell the
 718 dnl compiler that String is const.
 719 AC_DEFUN([CF_CONST_X_STRING],
 720 [
 721 AC_REQUIRE([AC_PATH_XTRA])
 722
 723 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
 724
 725 AC_TRY_COMPILE(
 726 [
 727 #include <stdlib.h>
 728 #include <X11/Intrinsic.h>
 729 ],
 730 [String foo = malloc(1); free((void*)foo)],[
 731
 732 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
 733         AC_TRY_COMPILE(
 734                 [
 735 #undef  _CONST_X_STRING
 736 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
 737 #undef  XTSTRINGDEFINES /* X11R5 and later */
 738 #include <stdlib.h>
 739 #include <X11/Intrinsic.h>
 740                 ],[String foo = malloc(1); *foo = 0],[
 741                         cf_cv_const_x_string=no
 742                 ],[
 743                         cf_cv_const_x_string=yes
 744                 ])
 745 ])
 746
 747 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
 748
 749 case "$cf_cv_const_x_string" in
 750 (no)
 751         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
 752         ;;
 753 (*)
 754         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
 755         ;;
 756 esac
 757
 758 ])
 759 ])dnl
 760 dnl ---------------------------------------------------------------------------
 761 dnl CF_CURSES_ACS_MAP version: 8 updated: 2021/01/04 19:45:09
 762 dnl -----------------
 763 dnl Check for likely values of acs_map[]:
 764 AC_DEFUN([CF_CURSES_ACS_MAP],
 765 [
 766 AC_REQUIRE([CF_NCURSES_WRAP_PREFIX])dnl
 767 AC_CACHE_CHECK(for alternate character set array, cf_cv_curses_acs_map,[
 768 cf_cv_curses_acs_map=unknown
 769 for name in acs_map _acs_map __acs_map ${NCURSES_WRAP_PREFIX}acs_map
 770 do
 771 AC_TRY_LINK([
 772 #include <${cf_cv_ncurses_header:-curses.h}>
 773 ],[
 774 ${name}['k'] = ACS_PLUS
 775 ],[cf_cv_curses_acs_map=$name; break])
 776 done
 777 ])
 778
 779 test "$cf_cv_curses_acs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_ACS_ARRAY,$cf_cv_curses_acs_map,[Define as needed to override ncurses prefix _nc_])
 780 ])
 781 dnl ---------------------------------------------------------------------------
 782 dnl CF_CURSES_CHECK_DATA version: 10 updated: 2021/01/04 19:45:09
 783 dnl --------------------
 784 dnl Check if curses.h defines the given data/variable.
 785 dnl Use this after CF_NCURSES_CONFIG or CF_CURSES_CONFIG.
 786 dnl
 787 dnl $1 = data item(s) to check for
 788 dnl $2 = action on success, e.g., "break" to quit checking a series of choices
 789 AC_DEFUN([CF_CURSES_CHECK_DATA],
 790 [
 791 for cf_data in $1
 792 do
 793 AC_MSG_CHECKING(for data $cf_data declaration in ${cf_cv_ncurses_header:-curses.h})
 794
 795 AC_TRY_COMPILE(CF__CURSES_HEAD,
 796 CF__CURSES_DATA(foo,$cf_data)
 797 ,[cf_result=yes
 798 ],[cf_result=no])
 799 AC_MSG_RESULT($cf_result)
 800
 801 if test "$cf_result" = yes ; then
 802         CF_UPPER(cf_result,have_curses_data_$cf_data)
 803         AC_DEFINE_UNQUOTED($cf_result)
 804         ifelse($2,,,[$2])
 805 else
 806         AC_MSG_CHECKING(for data $cf_data in library)
 807         # BSD linkers insist on making weak linkage, but resolve at runtime.
 808         AC_TRY_RUN(CF__CURSES_HEAD
 809 [
 810 extern char $cf_data;
 811 int main(void)
 812 {
 813         ]CF__CURSES_DATA(foo,$cf_data)[
 814         ${cf_cv_main_return:-return}(foo == 0);
 815 }],[cf_result=yes
 816 ],[cf_result=no],[
 817         # cross-compiling
 818         AC_TRY_LINK(CF__CURSES_HEAD
 819 [extern char $cf_data;],[
 820         do {
 821                 ]CF__CURSES_DATA(foo,$cf_data)[
 822                 ${cf_cv_main_return:-return}(foo == 0);
 823         } while (0)
 824 ],[cf_result=yes],[cf_result=no])
 825 ])
 826         AC_MSG_RESULT($cf_result)
 827         if test "$cf_result" = yes ; then
 828                 CF_UPPER(cf_result,decl_curses_data_$cf_data)
 829                 AC_DEFINE_UNQUOTED($cf_result)
 830                 # do not exit loop here, since we prefer system's declarations
 831         fi
 832 fi
 833 done
 834 ])dnl
 835 dnl ---------------------------------------------------------------------------
 836 dnl CF_CURSES_CHECK_TYPE version: 5 updated: 2021/01/04 19:45:09
 837 dnl --------------------
 838 dnl Check if curses.h defines the given type
 839 AC_DEFUN([CF_CURSES_CHECK_TYPE],
 840 [
 841 AC_MSG_CHECKING(for type $1 in ${cf_cv_ncurses_header:-curses.h})
 842 AC_TRY_COMPILE([
 843 #ifndef _XOPEN_SOURCE_EXTENDED
 844 #define _XOPEN_SOURCE_EXTENDED
 845 #endif
 846 #include <${cf_cv_ncurses_header:-curses.h}>],[
 847 $1 foo
 848 ],cf_result=yes,cf_result=no)
 849 AC_MSG_RESULT($cf_result)
 850 if test "$cf_result" = yes ; then
 851         CF_UPPER(cf_result,have_type_$1)
 852         AC_DEFINE_UNQUOTED($cf_result,1,[Define to 1 if we have type $1])
 853 else
 854         AC_DEFINE_UNQUOTED($1,$2,[Define to appropriate type if $1 is not declared])
 855 fi
 856 ])dnl
 857 dnl ---------------------------------------------------------------------------
 858 dnl CF_CURSES_CONFIG version: 2 updated: 2006/10/29 11:06:27
 859 dnl ----------------
 860 dnl Tie together the configure-script macros for curses.  It may be ncurses,
 861 dnl but unless asked, we do not make a special search for ncurses.  However,
 862 dnl still check for the ncurses version number, for use in other macros.
 863 AC_DEFUN([CF_CURSES_CONFIG],
 864 [
 865 CF_CURSES_CPPFLAGS
 866 CF_NCURSES_VERSION
 867 CF_CURSES_LIBS
 868 ])dnl
 869 dnl ---------------------------------------------------------------------------
 870 dnl CF_CURSES_CPPFLAGS version: 14 updated: 2021/01/02 09:31:20
 871 dnl ------------------
 872 dnl Look for the curses headers.
 873 AC_DEFUN([CF_CURSES_CPPFLAGS],[
 874
 875 AC_CACHE_CHECK(for extra include directories,cf_cv_curses_incdir,[
 876 cf_cv_curses_incdir=no
 877 case "$host_os" in
 878 (hpux10.*)
 879         if test "x$cf_cv_screen" = "xcurses_colr"
 880         then
 881                 test -d /usr/include/curses_colr && \
 882                 cf_cv_curses_incdir="-I/usr/include/curses_colr"
 883         fi
 884         ;;
 885 (sunos3*|sunos4*)
 886         if test "x$cf_cv_screen" = "xcurses_5lib"
 887         then
 888                 test -d /usr/5lib && \
 889                 test -d /usr/5include && \
 890                 cf_cv_curses_incdir="-I/usr/5include"
 891         fi
 892         ;;
 893 esac
 894 ])
 895 if test "$cf_cv_curses_incdir" != no
 896 then
 897         CF_APPEND_TEXT(CPPFLAGS,$cf_cv_curses_incdir)
 898 fi
 899
 900 CF_CURSES_HEADER
 901 CF_TERM_HEADER
 902 ])dnl
 903 dnl ---------------------------------------------------------------------------
 904 dnl CF_CURSES_FUNCS version: 20 updated: 2020/12/31 20:19:42
 905 dnl ---------------
 906 dnl Curses-functions are a little complicated, since a lot of them are macros.
 907 AC_DEFUN([CF_CURSES_FUNCS],
 908 [
 909 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 910 AC_REQUIRE([CF_XOPEN_CURSES])
 911 AC_REQUIRE([CF_CURSES_TERM_H])
 912 AC_REQUIRE([CF_CURSES_UNCTRL_H])
 913 for cf_func in $1
 914 do
 915         CF_UPPER(cf_tr_func,$cf_func)
 916         AC_MSG_CHECKING(for ${cf_func})
 917         CF_MSG_LOG(${cf_func})
 918         AC_CACHE_VAL(cf_cv_func_$cf_func,[
 919                 eval cf_result='$ac_cv_func_'$cf_func
 920                 if test ".$cf_result" != ".no"; then
 921                         AC_TRY_LINK(CF__CURSES_HEAD,
 922                         [
 923 #ifndef ${cf_func}
 924 long foo = (long)(&${cf_func});
 925 fprintf(stderr, "testing linkage of $cf_func:%p\\n", (void *)foo);
 926 if (foo + 1234L > 5678L)
 927         ${cf_cv_main_return:-return}(foo != 0);
 928 #endif
 929                         ],
 930                         [cf_result=yes],
 931                         [cf_result=no])
 932                 fi
 933                 eval 'cf_cv_func_'$cf_func'="$cf_result"'
 934         ])
 935         # use the computed/retrieved cache-value:
 936         eval 'cf_result=$cf_cv_func_'$cf_func
 937         AC_MSG_RESULT($cf_result)
 938         if test "$cf_result" != no; then
 939                 AC_DEFINE_UNQUOTED(HAVE_${cf_tr_func})
 940         fi
 941 done
 942 ])dnl
 943 dnl ---------------------------------------------------------------------------
 944 dnl CF_CURSES_HEADER version: 6 updated: 2022/12/02 20:06:52
 945 dnl ----------------
 946 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
 947 dnl variations of ncurses' installs.
 948 dnl
 949 dnl $1 = ncurses when looking for ncurses, or is empty
 950 AC_DEFUN([CF_CURSES_HEADER],[
 951 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
 952 cf_cv_ncurses_header=none
 953 for cf_header in \
 954         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
 955         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
 956 do
 957 AC_TRY_COMPILE([#include <${cf_header}>],
 958         [initscr(); endwin()],
 959         [cf_cv_ncurses_header=$cf_header; break],[])
 960 done
 961 ])
 962
 963 if test "$cf_cv_ncurses_header" = none ; then
 964         AC_MSG_ERROR(No curses header-files found)
 965 fi
 966
 967 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
 968 AC_CHECK_HEADERS($cf_cv_ncurses_header)
 969 ])dnl
 970 dnl ---------------------------------------------------------------------------
 971 dnl CF_CURSES_LIBS version: 45 updated: 2022/12/02 20:06:52
 972 dnl --------------
 973 dnl Look for the curses libraries.  Older curses implementations may require
 974 dnl termcap/termlib to be linked as well.  Call CF_CURSES_CPPFLAGS first.
 975 AC_DEFUN([CF_CURSES_LIBS],[
 976
 977 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 978 AC_MSG_CHECKING(if we have identified curses libraries)
 979 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 980         [initscr(); endwin()],
 981         cf_result=yes,
 982         cf_result=no)
 983 AC_MSG_RESULT($cf_result)
 984
 985 if test "$cf_result" = no ; then
 986 case "$host_os" in
 987 (freebsd*)
 988         AC_CHECK_LIB(mytinfo,tgoto,[CF_ADD_LIBS(-lmytinfo)])
 989         ;;
 990 (hpux10.*)
 991         # Looking at HPUX 10.20, the Hcurses library is the oldest (1997), cur_colr
 992         # next (1998), and xcurses "newer" (2000).  There is no header file for
 993         # Hcurses; the subdirectory curses_colr has the headers (curses.h and
 994         # term.h) for cur_colr
 995         if test "x$cf_cv_screen" = "xcurses_colr"
 996         then
 997                 AC_CHECK_LIB(cur_colr,initscr,[
 998                         CF_ADD_LIBS(-lcur_colr)
 999                         ac_cv_func_initscr=yes
1000                         ],[
1001                 AC_CHECK_LIB(Hcurses,initscr,[
1002                         # HP's header uses __HP_CURSES, but user claims _HP_CURSES.
1003                         CF_ADD_LIBS(-lHcurses)
1004                         CF_APPEND_TEXT(CPPFLAGS,-D__HP_CURSES -D_HP_CURSES)
1005                         ac_cv_func_initscr=yes
1006                         ])])
1007         fi
1008         ;;
1009 (linux*)
1010         case `arch 2>/dev/null` in
1011         (x86_64)
1012                 if test -d /lib64
1013                 then
1014                         CF_ADD_LIBDIR(/lib64)
1015                 else
1016                         CF_ADD_LIBDIR(/lib)
1017                 fi
1018                 ;;
1019         (*)
1020                 CF_ADD_LIBDIR(/lib)
1021                 ;;
1022         esac
1023         ;;
1024 (sunos3*|sunos4*)
1025         if test "x$cf_cv_screen" = "xcurses_5lib"
1026         then
1027                 if test -d /usr/5lib ; then
1028                         CF_ADD_LIBDIR(/usr/5lib)
1029                         CF_ADD_LIBS(-lcurses -ltermcap)
1030                 fi
1031         fi
1032         ac_cv_func_initscr=yes
1033         ;;
1034 esac
1035
1036 if test ".$ac_cv_func_initscr" != .yes ; then
1037         cf_save_LIBS="$LIBS"
1038
1039         if test ".${cf_cv_ncurses_version:-no}" != .no
1040         then
1041                 cf_check_list="ncurses curses cursesX"
1042         else
1043                 cf_check_list="cursesX curses ncurses"
1044         fi
1045
1046         # Check for library containing tgoto.  Do this before curses library
1047         # because it may be needed to link the test-case for initscr.
1048         if test "x$cf_term_lib" = x
1049         then
1050                 AC_CHECK_FUNC(tgoto,[cf_term_lib=predefined],[
1051                         for cf_term_lib in $cf_check_list otermcap termcap tinfo termlib unknown
1052                         do
1053                                 AC_CHECK_LIB($cf_term_lib,tgoto,[
1054                                         : "${cf_nculib_root:=$cf_term_lib}"
1055                                         break
1056                                 ])
1057                         done
1058                 ])
1059         fi
1060
1061         # Check for library containing initscr
1062         test "$cf_term_lib" != predefined && test "$cf_term_lib" != unknown && LIBS="-l$cf_term_lib $cf_save_LIBS"
1063         if test "x$cf_curs_lib" = x
1064         then
1065                 for cf_curs_lib in $cf_check_list xcurses jcurses pdcurses unknown
1066                 do
1067                         LIBS="-l$cf_curs_lib $cf_save_LIBS"
1068                         if test "$cf_term_lib" = unknown || test "$cf_term_lib" = "$cf_curs_lib" ; then
1069                                 AC_MSG_CHECKING(if we can link with $cf_curs_lib library)
1070                                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
1071                                         [initscr()],
1072                                         [cf_result=yes],
1073                                         [cf_result=no])
1074                                 AC_MSG_RESULT($cf_result)
1075                                 test "$cf_result" = yes && break
1076                         elif test "$cf_curs_lib" = "$cf_term_lib" ; then
1077                                 cf_result=no
1078                         elif test "$cf_term_lib" != predefined ; then
1079                                 AC_MSG_CHECKING(if we need both $cf_curs_lib and $cf_term_lib libraries)
1080                                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
1081                                         [initscr(); endwin();],
1082                                         [cf_result=no],
1083                                         [
1084                                         LIBS="-l$cf_curs_lib -l$cf_term_lib $cf_save_LIBS"
1085                                         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
1086                                                 [initscr()],
1087                                                 [cf_result=yes],
1088                                                 [cf_result=error])
1089                                         ])
1090                                 AC_MSG_RESULT($cf_result)
1091                                 test "$cf_result" != error && break
1092                         fi
1093                 done
1094         fi
1095         test "$cf_curs_lib" = unknown && AC_MSG_ERROR(no curses library found)
1096 fi
1097 fi
1098
1099 ])dnl
1100 dnl ---------------------------------------------------------------------------
1101 dnl CF_CURSES_TERM_H version: 16 updated: 2024/01/07 06:34:16
1102 dnl ----------------
1103 dnl SVr4 curses should have term.h as well (where it puts the definitions of
1104 dnl the low-level interface).  This may not be true in old/broken implementations,
1105 dnl as well as in misconfigured systems (e.g., gcc configured for Solaris 2.4
1106 dnl running with Solaris 2.5.1).
1107 AC_DEFUN([CF_CURSES_TERM_H],
1108 [
1109 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
1110
1111 AC_CACHE_CHECK(for term.h, cf_cv_term_header,[
1112
1113 # If we found <ncurses/curses.h>, look for <ncurses/term.h>, but always look
1114 # for <term.h> if we do not find the variant.
1115
1116 cf_header_list="term.h ncurses/term.h ncursesw/term.h"
1117
1118 case "${cf_cv_ncurses_header:-curses.h}" in
1119 (*/*)
1120         cf_header_item=`echo "${cf_cv_ncurses_header:-curses.h}" | sed -e 's%\..*%%' -e 's%/.*%/%'`term.h
1121         cf_header_list="$cf_header_item $cf_header_list"
1122         ;;
1123 esac
1124
1125 for cf_header in $cf_header_list
1126 do
1127         AC_TRY_COMPILE([
1128 #include <${cf_cv_ncurses_header:-curses.h}>
1129 #include <${cf_header}>],
1130         [WINDOW *x; (void)x],
1131         [cf_cv_term_header=$cf_header
1132          break],
1133         [cf_cv_term_header=no])
1134 done
1135
1136 case "$cf_cv_term_header" in
1137 (no)
1138         # If curses is ncurses, some packagers still mess it up by trying to make
1139         # us use GNU termcap.  This handles the most common case.
1140         for cf_header in ncurses/term.h ncursesw/term.h
1141         do
1142                 AC_TRY_COMPILE([
1143 #include <${cf_cv_ncurses_header:-curses.h}>
1144 #ifdef NCURSES_VERSION
1145 #include <${cf_header}>
1146 #else
1147 #error expected NCURSES_VERSION to be defined
1148 #endif],
1149                         [WINDOW *x; (void)x],
1150                         [cf_cv_term_header=$cf_header
1151                          break],
1152                         [cf_cv_term_header=no])
1153         done
1154         ;;
1155 esac
1156 ])
1157
1158 case "$cf_cv_term_header" in
1159 (term.h)
1160         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
1161         ;;
1162 (ncurses/term.h)
1163         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
1164         ;;
1165 (ncursesw/term.h)
1166         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
1167         ;;
1168 esac
1169 ])dnl
1170 dnl ---------------------------------------------------------------------------
1171 dnl CF_CURSES_UNCTRL_H version: 8 updated: 2021/01/02 09:31:20
1172 dnl ------------------
1173 dnl Any X/Open curses implementation must have unctrl.h, but ncurses packages
1174 dnl may put it in a subdirectory (along with ncurses' other headers, of
1175 dnl course).  Packages which put the headers in inconsistent locations are
1176 dnl broken).
1177 AC_DEFUN([CF_CURSES_UNCTRL_H],
1178 [
1179 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
1180
1181 AC_CACHE_CHECK(for unctrl.h, cf_cv_unctrl_header,[
1182
1183 # If we found <ncurses/curses.h>, look for <ncurses/unctrl.h>, but always look
1184 # for <unctrl.h> if we do not find the variant.
1185
1186 cf_header_list="unctrl.h ncurses/unctrl.h ncursesw/unctrl.h"
1187
1188 case "${cf_cv_ncurses_header:-curses.h}" in
1189 (*/*)
1190         cf_header_item=`echo "${cf_cv_ncurses_header:-curses.h}" | sed -e 's%\..*%%' -e 's%/.*%/%'`unctrl.h
1191         cf_header_list="$cf_header_item $cf_header_list"
1192         ;;
1193 esac
1194
1195 for cf_header in $cf_header_list
1196 do
1197         AC_TRY_COMPILE([
1198 #include <${cf_cv_ncurses_header:-curses.h}>
1199 #include <${cf_header}>],
1200         [WINDOW *x; (void)x],
1201         [cf_cv_unctrl_header=$cf_header
1202          break],
1203         [cf_cv_unctrl_header=no])
1204 done
1205 ])
1206
1207 case "$cf_cv_unctrl_header" in
1208 (no)
1209         AC_MSG_WARN(unctrl.h header not found)
1210         ;;
1211 esac
1212
1213 case "$cf_cv_unctrl_header" in
1214 (unctrl.h)
1215         AC_DEFINE(HAVE_UNCTRL_H,1,[Define to 1 if we have unctrl.h])
1216         ;;
1217 (ncurses/unctrl.h)
1218         AC_DEFINE(HAVE_NCURSES_UNCTRL_H,1,[Define to 1 if we have ncurses/unctrl.h])
1219         ;;
1220 (ncursesw/unctrl.h)
1221         AC_DEFINE(HAVE_NCURSESW_UNCTRL_H,1,[Define to 1 if we have ncursesw/unctrl.h])
1222         ;;
1223 esac
1224 ])dnl
1225 dnl ---------------------------------------------------------------------------
1226 dnl CF_CURSES_WACS_MAP version: 8 updated: 2021/01/04 19:45:09
1227 dnl ------------------
1228 dnl Check for likely values of wacs_map[].
1229 AC_DEFUN([CF_CURSES_WACS_MAP],
1230 [
1231 AC_CACHE_CHECK(for wide alternate character set array, cf_cv_curses_wacs_map,[
1232         cf_cv_curses_wacs_map=unknown
1233         for name in wacs_map _wacs_map __wacs_map _nc_wacs _wacs_char
1234         do
1235         AC_TRY_LINK([
1236 #ifndef _XOPEN_SOURCE_EXTENDED
1237 #define _XOPEN_SOURCE_EXTENDED
1238 #endif
1239 #include <${cf_cv_ncurses_header:-curses.h}>],
1240         [void *foo = &(${name}['k']); (void)foo],
1241         [cf_cv_curses_wacs_map=$name
1242          break])
1243         done])
1244
1245 test "$cf_cv_curses_wacs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_WACS_ARRAY,$cf_cv_curses_wacs_map,[Define to name of (n)curses wide-character array])
1246 ])dnl
1247 dnl ---------------------------------------------------------------------------
1248 dnl CF_CURSES_WACS_SYMBOLS version: 4 updated: 2021/01/04 19:45:09
1249 dnl ----------------------
1250 dnl Do a check to see if the WACS_xxx constants are defined compatibly with
1251 dnl X/Open Curses.  In particular, NetBSD's implementation of the WACS_xxx
1252 dnl constants is broken since those constants do not point to cchar_t's.
1253 AC_DEFUN([CF_CURSES_WACS_SYMBOLS],
1254 [
1255 AC_REQUIRE([CF_CURSES_WACS_MAP])
1256
1257 AC_CACHE_CHECK(for wide alternate character constants, cf_cv_curses_wacs_symbols,[
1258 cf_cv_curses_wacs_symbols=no
1259 if test "$cf_cv_curses_wacs_map" != unknown
1260 then
1261         AC_TRY_LINK([
1262 #ifndef _XOPEN_SOURCE_EXTENDED
1263 #define _XOPEN_SOURCE_EXTENDED
1264 #endif
1265 #include <${cf_cv_ncurses_header:-curses.h}>],
1266         [cchar_t *foo = WACS_PLUS;
1267          ${cf_cv_curses_wacs_map}['k'] = *WACS_PLUS; (void)foo],
1268         [cf_cv_curses_wacs_symbols=yes])
1269 else
1270         AC_TRY_LINK([
1271 #ifndef _XOPEN_SOURCE_EXTENDED
1272 #define _XOPEN_SOURCE_EXTENDED
1273 #endif
1274 #include <${cf_cv_ncurses_header:-curses.h}>],
1275         [cchar_t *foo = WACS_PLUS; (void)foo],
1276         [cf_cv_curses_wacs_symbols=yes])
1277 fi
1278 ])
1279
1280 test "$cf_cv_curses_wacs_symbols" != no && AC_DEFINE(CURSES_WACS_SYMBOLS,1,[Define to 1 if (n)curses supports wide-character WACS_ symbols])
1281 ])dnl
1282 dnl ---------------------------------------------------------------------------
1283 dnl CF_DIRNAME version: 5 updated: 2020/12/31 20:19:42
1284 dnl ----------
1285 dnl "dirname" is not portable, so we fake it with a shell script.
1286 AC_DEFUN([CF_DIRNAME],[$1=`echo "$2" | sed -e 's%/[[^/]]*$%%'`])dnl
1287 dnl ---------------------------------------------------------------------------
1288 dnl CF_DISABLE_ECHO version: 14 updated: 2021/09/04 06:35:04
1289 dnl ---------------
1290 dnl You can always use "make -n" to see the actual options, but it is hard to
1291 dnl pick out/analyze warning messages when the compile-line is long.
1292 dnl
1293 dnl Sets:
1294 dnl     ECHO_LT - symbol to control if libtool is verbose
1295 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1296 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1297 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1298 dnl     ECHO_CC - symbol to put before any "cc" line
1299 dnl
1300 AC_DEFUN([CF_DISABLE_ECHO],[
1301 AC_MSG_CHECKING(if you want to see long compiling messages)
1302 CF_ARG_DISABLE(echo,
1303         [  --disable-echo          do not display "compiling" commands],
1304         [
1305         ECHO_LT='--silent'
1306         ECHO_LD='@echo linking [$]@;'
1307         RULE_CC='@echo compiling [$]<'
1308         SHOW_CC='@echo compiling [$]@'
1309         ECHO_CC='@'
1310 ],[
1311         ECHO_LT=''
1312         ECHO_LD=''
1313         RULE_CC=''
1314         SHOW_CC=''
1315         ECHO_CC=''
1316 ])
1317 AC_MSG_RESULT($enableval)
1318 AC_SUBST(ECHO_LT)
1319 AC_SUBST(ECHO_LD)
1320 AC_SUBST(RULE_CC)
1321 AC_SUBST(SHOW_CC)
1322 AC_SUBST(ECHO_CC)
1323 ])dnl
1324 dnl ---------------------------------------------------------------------------
1325 dnl CF_DISABLE_LEAKS version: 9 updated: 2021/04/03 16:41:50
1326 dnl ----------------
1327 dnl Combine no-leak checks with the libraries or tools that are used for the
1328 dnl checks.
1329 AC_DEFUN([CF_DISABLE_LEAKS],[
1330
1331 AC_REQUIRE([CF_WITH_DMALLOC])
1332 AC_REQUIRE([CF_WITH_DBMALLOC])
1333 AC_REQUIRE([CF_WITH_VALGRIND])
1334
1335 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1336 AC_ARG_ENABLE(leaks,
1337         [  --disable-leaks         test: free permanent memory, analyze leaks],
1338         [enable_leaks=$enableval],
1339         [enable_leaks=yes])
1340 dnl with_no_leaks is more readable...
1341 if test "x$enable_leaks" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi
1342 AC_MSG_RESULT($with_no_leaks)
1343
1344 if test "$enable_leaks" = no ; then
1345         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1346         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1347 fi
1348 ])dnl
1349 dnl ---------------------------------------------------------------------------
1350 dnl CF_DISABLE_RPATH_HACK version: 3 updated: 2021/01/05 20:14:44
1351 dnl ---------------------
1352 dnl The rpath-hack makes it simpler to build programs, particularly with the
1353 dnl *BSD ports which may have essential libraries in unusual places.  But it
1354 dnl can interfere with building an executable for the base system.  Use this
1355 dnl option in that case.
1356 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1357 [
1358 AC_MSG_CHECKING(if rpath-hack should be disabled)
1359 CF_ARG_DISABLE(rpath-hack,
1360         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1361         [enable_rpath_hack=no],
1362         [enable_rpath_hack=yes])
1363 dnl TODO - drop cf_disable_rpath_hack
1364 if test "x$enable_rpath_hack" = xno; then cf_disable_rpath_hack=yes; else cf_disable_rpath_hack=no; fi
1365 AC_MSG_RESULT($cf_disable_rpath_hack)
1366
1367 if test "$enable_rpath_hack" = yes ; then
1368         CF_RPATH_HACK
1369 fi
1370 ])
1371 dnl ---------------------------------------------------------------------------
1372 dnl CF_ENABLE_STRING_HACKS version: 6 updated: 2021/01/05 19:23:48
1373 dnl ----------------------
1374 dnl On a few platforms, the compiler and/or loader nags with untruthful
1375 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1376 dnl and implying that most uses of the recommended alternatives are correct.
1377 dnl
1378 dnl Factually speaking, no one has actually counted the number of uses of these
1379 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1380 dnl instances are meaningless compared to the hundreds of millions of lines of
1381 dnl existing C code.
1382 dnl
1383 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1384 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1385 dnl standard - but evolved through phases, and older implementations are likely
1386 dnl to yield surprising results, as documented in manpages on various systems.
1387 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1388 [
1389 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1390 AC_ARG_ENABLE(string-hacks,
1391         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1392         [enable_string_hacks=$enableval],
1393         [enable_string_hacks=no])
1394 AC_MSG_RESULT($enable_string_hacks)
1395
1396 if test "x$enable_string_hacks" = "xyes"; then
1397         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1398         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1399         AC_CHECK_FUNC(strlcat,[
1400                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1401                 ],[
1402                 AC_CHECK_LIB(bsd,strlcat,[
1403                         CF_ADD_LIB(bsd)
1404                         AC_CHECK_HEADERS(bsd/string.h)
1405                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1406                         ])
1407                 ])
1408         AC_CHECK_FUNCS( strlcpy snprintf )
1409 fi
1410 ])dnl
1411 dnl ---------------------------------------------------------------------------
1412 dnl CF_ENABLE_WARNINGS version: 9 updated: 2021/01/05 19:40:50
1413 dnl ------------------
1414 dnl Configure-option to enable gcc warnings
1415 dnl
1416 dnl $1 = extra options to add, if supported
1417 dnl $2 = option for checking attributes.  By default, this is done when
1418 dnl      warnings are enabled.  For other values:
1419 dnl      yes: always do this, e.g., to use in generated library-headers
1420 dnl      no: never do this
1421 AC_DEFUN([CF_ENABLE_WARNINGS],[
1422 if test "$GCC" = yes || test "$GXX" = yes
1423 then
1424 CF_FIX_WARNINGS(CFLAGS)
1425 CF_FIX_WARNINGS(CPPFLAGS)
1426 CF_FIX_WARNINGS(LDFLAGS)
1427 AC_MSG_CHECKING(if you want to turn on gcc warnings)
1428 CF_ARG_ENABLE(warnings,
1429         [  --enable-warnings       test: turn on gcc compiler warnings],
1430         [enable_warnings=yes],
1431         [enable_warnings=no])
1432 AC_MSG_RESULT($enable_warnings)
1433 if test "$enable_warnings" = "yes"
1434 then
1435         ifelse($2,,[CF_GCC_ATTRIBUTES])
1436         CF_GCC_WARNINGS($1)
1437 fi
1438 ifelse($2,yes,[CF_GCC_ATTRIBUTES])
1439 fi
1440 ])dnl
1441 dnl ---------------------------------------------------------------------------
1442 dnl CF_FIND_LIBRARY version: 11 updated: 2021/01/02 09:31:20
1443 dnl ---------------
1444 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
1445 dnl prefer a standard location, and use -L options only if we do not find the
1446 dnl library in the standard library location(s).
1447 dnl     $1 = library name
1448 dnl     $2 = library class, usually the same as library name
1449 dnl     $3 = includes
1450 dnl     $4 = code fragment to compile/link
1451 dnl     $5 = corresponding function-name
1452 dnl     $6 = flag, nonnull if failure should not cause an error-exit
1453 dnl
1454 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
1455 dnl to use a -L option.
1456 AC_DEFUN([CF_FIND_LIBRARY],
1457 [
1458         eval 'cf_cv_have_lib_'"$1"'=no'
1459         cf_libdir=""
1460         AC_CHECK_FUNC($5,
1461                 eval 'cf_cv_have_lib_'"$1"'=yes',[
1462                 cf_save_LIBS="$LIBS"
1463                 AC_MSG_CHECKING(for $5 in -l$1)
1464                 LIBS="-l$1 $LIBS"
1465                 AC_TRY_LINK([$3],[$4],
1466                         [AC_MSG_RESULT(yes)
1467                          eval 'cf_cv_have_lib_'"$1"'=yes'
1468                         ],
1469                         [AC_MSG_RESULT(no)
1470                         CF_LIBRARY_PATH(cf_search,$2)
1471                         for cf_libdir in $cf_search
1472                         do
1473                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
1474                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
1475                                 AC_TRY_LINK([$3],[$4],
1476                                         [AC_MSG_RESULT(yes)
1477                                          eval 'cf_cv_have_lib_'"$1"'=yes'
1478                                          break],
1479                                         [AC_MSG_RESULT(no)
1480                                          LIBS="$cf_save_LIBS"])
1481                         done
1482                         ])
1483                 ])
1484 eval 'cf_found_library="[$]cf_cv_have_lib_'"$1"\"
1485 ifelse($6,,[
1486 if test "$cf_found_library" = no ; then
1487         AC_MSG_ERROR(Cannot link $1 library)
1488 fi
1489 ])
1490 ])dnl
1491 dnl ---------------------------------------------------------------------------
1492 dnl CF_FIND_LINKAGE version: 22 updated: 2020/12/31 20:19:42
1493 dnl ---------------
1494 dnl Find a library (specifically the linkage used in the code fragment),
1495 dnl searching for it if it is not already in the library path.
1496 dnl See also CF_ADD_SEARCHPATH.
1497 dnl
1498 dnl Parameters (4-on are optional):
1499 dnl     $1 = headers for library entrypoint
1500 dnl     $2 = code fragment for library entrypoint
1501 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1502 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1503 dnl     $5 = action to perform if not successful
1504 dnl     $6 = module name, if not the same as the library name
1505 dnl     $7 = extra libraries
1506 dnl
1507 dnl Sets these variables:
1508 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1509 dnl     $cf_cv_header_path_$3 - include-directory if needed
1510 dnl     $cf_cv_library_path_$3 - library-directory if needed
1511 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1512 AC_DEFUN([CF_FIND_LINKAGE],[
1513
1514 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1515 # will be set on completion of the AC_TRY_LINK below.
1516 cf_cv_header_path_$3=
1517 cf_cv_library_path_$3=
1518
1519 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1520
1521 cf_save_LIBS="$LIBS"
1522
1523 AC_TRY_LINK([$1],[$2],[
1524         cf_cv_find_linkage_$3=yes
1525         cf_cv_header_path_$3=/usr/include
1526         cf_cv_library_path_$3=/usr/lib
1527 ],[
1528
1529 LIBS="-l$3 $7 $cf_save_LIBS"
1530
1531 AC_TRY_LINK([$1],[$2],[
1532         cf_cv_find_linkage_$3=yes
1533         cf_cv_header_path_$3=/usr/include
1534         cf_cv_library_path_$3=/usr/lib
1535         cf_cv_library_file_$3="-l$3"
1536 ],[
1537         cf_cv_find_linkage_$3=no
1538         LIBS="$cf_save_LIBS"
1539
1540         CF_VERBOSE(find linkage for $3 library)
1541         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1542
1543         cf_save_CPPFLAGS="$CPPFLAGS"
1544         cf_test_CPPFLAGS="$CPPFLAGS"
1545
1546         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1547         for cf_cv_header_path_$3 in $cf_search
1548         do
1549                 if test -d "$cf_cv_header_path_$3" ; then
1550                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1551                         CPPFLAGS="$cf_save_CPPFLAGS"
1552                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
1553                         AC_TRY_COMPILE([$1],[$2],[
1554                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1555                                 cf_cv_find_linkage_$3=maybe
1556                                 cf_test_CPPFLAGS="$CPPFLAGS"
1557                                 break],[
1558                                 CPPFLAGS="$cf_save_CPPFLAGS"
1559                                 ])
1560                 fi
1561         done
1562
1563         if test "$cf_cv_find_linkage_$3" = maybe ; then
1564
1565                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1566
1567                 cf_save_LIBS="$LIBS"
1568                 cf_save_LDFLAGS="$LDFLAGS"
1569
1570                 ifelse([$6],,,[
1571                 CPPFLAGS="$cf_test_CPPFLAGS"
1572                 LIBS="-l$3 $7 $cf_save_LIBS"
1573                 AC_TRY_LINK([$1],[$2],[
1574                         CF_VERBOSE(... found $3 library in system)
1575                         cf_cv_find_linkage_$3=yes])
1576                         CPPFLAGS="$cf_save_CPPFLAGS"
1577                         LIBS="$cf_save_LIBS"
1578                         ])
1579
1580                 if test "$cf_cv_find_linkage_$3" != yes ; then
1581                         CF_LIBRARY_PATH(cf_search,$3)
1582                         for cf_cv_library_path_$3 in $cf_search
1583                         do
1584                                 if test -d "$cf_cv_library_path_$3" ; then
1585                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1586                                         CPPFLAGS="$cf_test_CPPFLAGS"
1587                                         LIBS="-l$3 $7 $cf_save_LIBS"
1588                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1589                                         AC_TRY_LINK([$1],[$2],[
1590                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1591                                         cf_cv_find_linkage_$3=yes
1592                                         cf_cv_library_file_$3="-l$3"
1593                                         break],[
1594                                         CPPFLAGS="$cf_save_CPPFLAGS"
1595                                         LIBS="$cf_save_LIBS"
1596                                         LDFLAGS="$cf_save_LDFLAGS"
1597                                         ])
1598                                 fi
1599                         done
1600                         CPPFLAGS="$cf_save_CPPFLAGS"
1601                         LDFLAGS="$cf_save_LDFLAGS"
1602                 fi
1603
1604         else
1605                 cf_cv_find_linkage_$3=no
1606         fi
1607         ],$7)
1608 ])
1609
1610 LIBS="$cf_save_LIBS"
1611
1612 if test "$cf_cv_find_linkage_$3" = yes ; then
1613 ifelse([$4],,[
1614         CF_ADD_INCDIR($cf_cv_header_path_$3)
1615         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1616         CF_ADD_LIB($3)
1617 ],[$4])
1618 else
1619 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1620 fi
1621 ])dnl
1622 dnl ---------------------------------------------------------------------------
1623 dnl CF_FIX_WARNINGS version: 4 updated: 2021/12/16 18:22:31
1624 dnl ---------------
1625 dnl Warning flags do not belong in CFLAGS, CPPFLAGS, etc.  Any of gcc's
1626 dnl "-Werror" flags can interfere with configure-checks.  Those go into
1627 dnl EXTRA_CFLAGS.
1628 dnl
1629 dnl $1 = variable name to repair
1630 define([CF_FIX_WARNINGS],[
1631 if test "$GCC" = yes || test "$GXX" = yes
1632 then
1633         case [$]$1 in
1634         (*-Werror=*)
1635                 cf_temp_flags=
1636                 for cf_temp_scan in [$]$1
1637                 do
1638                         case "x$cf_temp_scan" in
1639                         (x-Werror=format*)
1640                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
1641                                 ;;
1642                         (x-Werror=*)
1643                                 CF_APPEND_TEXT(EXTRA_CFLAGS,$cf_temp_scan)
1644                                 ;;
1645                         (*)
1646                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
1647                                 ;;
1648                         esac
1649                 done
1650                 if test "x[$]$1" != "x$cf_temp_flags"
1651                 then
1652                         CF_VERBOSE(repairing $1: [$]$1)
1653                         $1="$cf_temp_flags"
1654                         CF_VERBOSE(... fixed [$]$1)
1655                         CF_VERBOSE(... extra $EXTRA_CFLAGS)
1656                 fi
1657                 ;;
1658         esac
1659 fi
1660 AC_SUBST(EXTRA_CFLAGS)
1661 ])dnl
1662 dnl ---------------------------------------------------------------------------
1663 dnl CF_FUNC_CURSES_VERSION version: 9 updated: 2023/01/05 18:06:10
1664 dnl ----------------------
1665 dnl Solaris has a data item 'curses_version', which confuses AC_CHECK_FUNCS.
1666 dnl It's a character string "SVR4", not documented.
1667 AC_DEFUN([CF_FUNC_CURSES_VERSION],
1668 [
1669 AC_CACHE_CHECK(for function curses_version, cf_cv_func_curses_version,[
1670 AC_TRY_RUN([
1671 $ac_includes_default
1672
1673 #include <${cf_cv_ncurses_header:-curses.h}>
1674
1675 int main(void)
1676 {
1677         char temp[1024];
1678         sprintf(temp, "%.999s\\n", curses_version());
1679         ${cf_cv_main_return:-return}(0);
1680 }]
1681 ,[cf_cv_func_curses_version=yes]
1682 ,[cf_cv_func_curses_version=no]
1683 ,[cf_cv_func_curses_version=unknown])
1684 rm -f core])
1685 test "$cf_cv_func_curses_version" = yes && AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 if we have curses_version function])
1686 ])
1687 dnl ---------------------------------------------------------------------------
1688 dnl CF_FUNC_GETTIME version: 2 updated: 2023/02/25 08:45:56
1689 dnl ---------------
1690 dnl Check for gettimeofday or clock_gettime.  In 2023, the former is still more
1691 dnl widely supported, but "deprecated" (2008), so we will use the latter if it
1692 dnl is available, to reduce compiler warnings.
1693 AC_DEFUN([CF_FUNC_GETTIME],[
1694 AC_CACHE_CHECK(for clock_gettime,cf_cv_func_clock_gettime,[
1695                 AC_TRY_LINK([#include <time.h>],
1696                 [struct timespec ts;
1697                 int rc = clock_gettime(CLOCK_REALTIME, &ts); (void) rc; (void)ts],
1698                 [cf_cv_func_clock_gettime=yes],
1699                 [cf_cv_func_clock_gettime=no])
1700 ])
1701
1702 if test "$cf_cv_func_clock_gettime" = yes
1703 then
1704         AC_DEFINE(HAVE_CLOCK_GETTIME,1,[Define to 1 if we have clock_gettime function])
1705 else
1706 AC_CHECK_FUNC(gettimeofday,
1707         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1708
1709 AC_CHECK_LIB(bsd, gettimeofday,
1710         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1711         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1712 fi
1713 ])dnl
1714 dnl ---------------------------------------------------------------------------
1715 dnl CF_FUNC_OPENPTY version: 7 updated: 2023/12/03 09:21:34
1716 dnl ---------------
1717 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1718 dnl "util" library as well.
1719 AC_DEFUN([CF_FUNC_OPENPTY],
1720 [
1721 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1722 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1723         cf_save_LIBS="$LIBS"
1724         test "$cf_cv_lib_util" = yes && { CF_ADD_LIB(util) }
1725         for cf_header in pty.h libutil.h util.h
1726         do
1727         AC_TRY_LINK([
1728 #include <$cf_header>
1729 ],[
1730         int x = openpty((int *)0, (int *)0, (char *)0,
1731                                    (struct termios *)0, (struct winsize *)0);
1732         (void)x;
1733 ],[
1734                 cf_cv_func_openpty=$cf_header
1735                 break
1736 ],[
1737                 cf_cv_func_openpty=no
1738 ])
1739         done
1740         LIBS="$cf_save_LIBS"
1741 ])
1742 ])dnl
1743 dnl ---------------------------------------------------------------------------
1744 dnl CF_GCC_ATTRIBUTES version: 24 updated: 2021/03/20 12:00:25
1745 dnl -----------------
1746 dnl Test for availability of useful gcc __attribute__ directives to quiet
1747 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1748 dnl to documentation, unrecognized directives cause older compilers to barf.
1749 AC_DEFUN([CF_GCC_ATTRIBUTES],
1750 [AC_REQUIRE([AC_PROG_FGREP])dnl
1751 AC_REQUIRE([CF_C11_NORETURN])dnl
1752
1753 if test "$GCC" = yes || test "$GXX" = yes
1754 then
1755 cat > conftest.i <<EOF
1756 #ifndef GCC_PRINTF
1757 #define GCC_PRINTF 0
1758 #endif
1759 #ifndef GCC_SCANF
1760 #define GCC_SCANF 0
1761 #endif
1762 #ifndef GCC_NORETURN
1763 #define GCC_NORETURN /* nothing */
1764 #endif
1765 #ifndef GCC_UNUSED
1766 #define GCC_UNUSED /* nothing */
1767 #endif
1768 EOF
1769 if test "$GCC" = yes
1770 then
1771         AC_CHECKING([for $CC __attribute__ directives])
1772 cat > "conftest.$ac_ext" <<EOF
1773 #line __oline__ "${as_me:-configure}"
1774 #include <stdio.h>
1775 #include "confdefs.h"
1776 #include "conftest.h"
1777 #include "conftest.i"
1778 #if     GCC_PRINTF
1779 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1780 #else
1781 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1782 #endif
1783 #if     GCC_SCANF
1784 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1785 #else
1786 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1787 #endif
1788 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1789 extern GCC_NORETURN void oops(char *,...) GCC_PRINTFLIKE(1,2);
1790 extern GCC_NORETURN void foo(void);
1791 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
1792 EOF
1793         cf_printf_attribute=no
1794         cf_scanf_attribute=no
1795         for cf_attribute in scanf printf unused noreturn
1796         do
1797                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1798                 cf_directive="__attribute__(($cf_attribute))"
1799                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1800
1801                 case "$cf_attribute" in
1802                 (printf)
1803                         cf_printf_attribute=yes
1804                         cat >conftest.h <<EOF
1805 #define GCC_$cf_ATTRIBUTE 1
1806 EOF
1807                         ;;
1808                 (scanf)
1809                         cf_scanf_attribute=yes
1810                         cat >conftest.h <<EOF
1811 #define GCC_$cf_ATTRIBUTE 1
1812 EOF
1813                         ;;
1814                 (*)
1815                         cat >conftest.h <<EOF
1816 #define GCC_$cf_ATTRIBUTE $cf_directive
1817 EOF
1818                         ;;
1819                 esac
1820
1821                 if AC_TRY_EVAL(ac_compile); then
1822                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1823                         cat conftest.h >>confdefs.h
1824                         case "$cf_attribute" in
1825                         (noreturn)
1826                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1827                                 ;;
1828                         (printf)
1829                                 cf_value='/* nothing */'
1830                                 if test "$cf_printf_attribute" != no ; then
1831                                         cf_value='__attribute__((format(printf,fmt,var)))'
1832                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1833                                 fi
1834                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1835                                 ;;
1836                         (scanf)
1837                                 cf_value='/* nothing */'
1838                                 if test "$cf_scanf_attribute" != no ; then
1839                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1840                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1841                                 fi
1842                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1843                                 ;;
1844                         (unused)
1845                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1846                                 ;;
1847                         esac
1848                 fi
1849         done
1850 else
1851         ${FGREP-fgrep} define conftest.i >>confdefs.h
1852 fi
1853 rm -rf ./conftest*
1854 fi
1855 ])dnl
1856 dnl ---------------------------------------------------------------------------
1857 dnl CF_GCC_VERSION version: 9 updated: 2023/03/05 14:30:13
1858 dnl --------------
1859 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
1860 dnl compatible), attempt to determine if icc/clang is actually used.
1861 AC_DEFUN([CF_GCC_VERSION],[
1862 AC_REQUIRE([AC_PROG_CC])
1863 GCC_VERSION=none
1864 if test "$GCC" = yes ; then
1865         AC_MSG_CHECKING(version of $CC)
1866         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^[[^(]]*([[^)]][[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1867         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1868         AC_MSG_RESULT($GCC_VERSION)
1869 fi
1870 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1871 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1872 ])dnl
1873 dnl ---------------------------------------------------------------------------
1874 dnl CF_GCC_WARNINGS version: 41 updated: 2021/01/01 16:53:59
1875 dnl ---------------
1876 dnl Check if the compiler supports useful warning options.  There's a few that
1877 dnl we don't use, simply because they're too noisy:
1878 dnl
1879 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1880 dnl     -Winline (usually not worthwhile)
1881 dnl     -Wredundant-decls (system headers make this too noisy)
1882 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1883 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1884 dnl             is enabled for ncurses using "--enable-const".
1885 dnl     -pedantic
1886 dnl
1887 dnl Parameter:
1888 dnl     $1 is an optional list of gcc warning flags that a particular
1889 dnl             application might want to use, e.g., "no-unused" for
1890 dnl             -Wno-unused
1891 dnl Special:
1892 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1893 dnl
1894 AC_DEFUN([CF_GCC_WARNINGS],
1895 [
1896 AC_REQUIRE([CF_GCC_VERSION])
1897 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
1898 cat > "conftest.$ac_ext" <<EOF
1899 #line __oline__ "${as_me:-configure}"
1900 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1901 EOF
1902 if test "$INTEL_COMPILER" = yes
1903 then
1904 # The "-wdXXX" options suppress warnings:
1905 # remark #1419: external declaration in primary source file
1906 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1907 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1908 # remark #193: zero used for undefined preprocessing identifier
1909 # remark #593: variable "curs_sb_left_arrow" was set but never used
1910 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1911 # remark #869: parameter "tw" was never referenced
1912 # remark #981: operands are evaluated in unspecified order
1913 # warning #279: controlling expression is constant
1914
1915         AC_CHECKING([for $CC warning options])
1916         cf_save_CFLAGS="$CFLAGS"
1917         EXTRA_CFLAGS="$EXTRA_CFLAGS -Wall"
1918         for cf_opt in \
1919                 wd1419 \
1920                 wd1683 \
1921                 wd1684 \
1922                 wd193 \
1923                 wd593 \
1924                 wd279 \
1925                 wd810 \
1926                 wd869 \
1927                 wd981
1928         do
1929                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1930                 if AC_TRY_EVAL(ac_compile); then
1931                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1932                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1933                 fi
1934         done
1935         CFLAGS="$cf_save_CFLAGS"
1936 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
1937 then
1938         AC_CHECKING([for $CC warning options])
1939         cf_save_CFLAGS="$CFLAGS"
1940         cf_warn_CONST=""
1941         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1942         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1943         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1944         for cf_opt in W Wall \
1945                 Wbad-function-cast \
1946                 Wcast-align \
1947                 Wcast-qual \
1948                 Wdeclaration-after-statement \
1949                 Wextra \
1950                 Winline \
1951                 Wmissing-declarations \
1952                 Wmissing-prototypes \
1953                 Wnested-externs \
1954                 Wpointer-arith \
1955                 Wshadow \
1956                 Wstrict-prototypes \
1957                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
1958         do
1959                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1960                 if AC_TRY_EVAL(ac_compile); then
1961                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1962                         case "$cf_opt" in
1963                         (Winline)
1964                                 case "$GCC_VERSION" in
1965                                 ([[34]].*)
1966                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1967                                         continue;;
1968                                 esac
1969                                 ;;
1970                         (Wpointer-arith)
1971                                 case "$GCC_VERSION" in
1972                                 ([[12]].*)
1973                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1974                                         continue;;
1975                                 esac
1976                                 ;;
1977                         esac
1978                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1979                 fi
1980         done
1981         CFLAGS="$cf_save_CFLAGS"
1982 fi
1983 rm -rf ./conftest*
1984
1985 AC_SUBST(EXTRA_CFLAGS)
1986 ])dnl
1987 dnl ---------------------------------------------------------------------------
1988 dnl CF_GETOPT_HEADER version: 8 updated: 2021/06/19 19:16:16
1989 dnl ----------------
1990 dnl Check for getopt's variables which are commonly defined in stdlib.h,
1991 dnl unistd.h or (nonstandard) in getopt.h
1992 AC_DEFUN([CF_GETOPT_HEADER],
1993 [
1994 AC_HAVE_HEADERS(unistd.h getopt.h)
1995 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
1996 cf_cv_getopt_header=none
1997 for cf_header in stdio.h stdlib.h unistd.h getopt.h
1998 do
1999 AC_TRY_COMPILE([
2000 #include <$cf_header>],
2001 [int x = optind; char *y = optarg; (void)x; (void)y],
2002 [cf_cv_getopt_header=$cf_header
2003  break])
2004 done
2005 ])
2006 if test "$cf_cv_getopt_header" != none ; then
2007         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2008 fi
2009 if test "$cf_cv_getopt_header" = getopt.h ; then
2010         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2011 fi
2012 ])dnl
2013 dnl ---------------------------------------------------------------------------
2014 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
2015 dnl -------------
2016 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2017 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2018 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2019 dnl since it is interwoven with GNU extensions.
2020 dnl
2021 dnl Well, yes we could work around it...
2022 dnl
2023 dnl Parameters:
2024 dnl     $1 is the nominal value for _XOPEN_SOURCE
2025 AC_DEFUN([CF_GNU_SOURCE],
2026 [
2027 cf_gnu_xopen_source=ifelse($1,,500,$1)
2028
2029 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
2030 AC_TRY_COMPILE([#include <sys/types.h>],[
2031         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
2032                 return 0;
2033         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
2034                 return 0;
2035         #else
2036         #       error not GNU C library
2037         #endif],
2038         [cf_cv_gnu_library=yes],
2039         [cf_cv_gnu_library=no])
2040 ])
2041
2042 if test x$cf_cv_gnu_library = xyes; then
2043
2044         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
2045         # was changed to help a little.  newlib incorporated the change about 4
2046         # years later.
2047         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
2048                 cf_save="$CPPFLAGS"
2049                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
2050                 AC_TRY_COMPILE([#include <sys/types.h>],[
2051                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
2052                                 return 0;
2053                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
2054                                 return 0;
2055                         #else
2056                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
2057                         #endif],
2058                         [cf_cv_gnu_library_219=yes],
2059                         [cf_cv_gnu_library_219=no])
2060                 CPPFLAGS="$cf_save"
2061         ])
2062
2063         if test "x$cf_cv_gnu_library_219" = xyes; then
2064                 cf_save="$CPPFLAGS"
2065                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
2066                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
2067                         AC_TRY_COMPILE([
2068                                 #include <limits.h>
2069                                 #include <sys/types.h>
2070                                 ],[
2071                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
2072                                         return 0;
2073                                 #else
2074                                 #       error GNU C library is too old
2075                                 #endif],
2076                                 [cf_cv_gnu_dftsrc_219=yes],
2077                                 [cf_cv_gnu_dftsrc_219=no])
2078                         ])
2079                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
2080         else
2081                 cf_cv_gnu_dftsrc_219=maybe
2082         fi
2083
2084         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
2085
2086                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2087                 AC_TRY_COMPILE([#include <sys/types.h>],[
2088                         #ifndef _XOPEN_SOURCE
2089                         #error  expected _XOPEN_SOURCE to be defined
2090                         #endif],
2091                         [cf_cv_gnu_source=no],
2092                         [cf_save="$CPPFLAGS"
2093                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
2094                          AC_TRY_COMPILE([#include <sys/types.h>],[
2095                                 #ifdef _XOPEN_SOURCE
2096                                 #error  expected _XOPEN_SOURCE to be undefined
2097                                 #endif],
2098                                 [cf_cv_gnu_source=no],
2099                                 [cf_cv_gnu_source=yes])
2100                         CPPFLAGS="$cf_save"
2101                         ])
2102                 ])
2103
2104                 if test "$cf_cv_gnu_source" = yes
2105                 then
2106                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
2107                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
2108                         AC_TRY_COMPILE([#include <sys/types.h>],[
2109                                 #ifdef _DEFAULT_SOURCE
2110                                 #error  expected _DEFAULT_SOURCE to be undefined
2111                                 #endif],
2112                                 [cf_cv_default_source=no],
2113                                 [cf_cv_default_source=yes])
2114                         ])
2115                         if test "$cf_cv_default_source" = yes
2116                         then
2117                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
2118                         fi
2119                 fi
2120         fi
2121
2122 fi
2123 ])dnl
2124 dnl ---------------------------------------------------------------------------
2125 dnl CF_HEADER_PATH version: 15 updated: 2021/01/01 13:31:04
2126 dnl --------------
2127 dnl Construct a search-list of directories for a nonstandard header-file
2128 dnl
2129 dnl Parameters
2130 dnl     $1 = the variable to return as result
2131 dnl     $2 = the package name
2132 AC_DEFUN([CF_HEADER_PATH],
2133 [
2134 $1=
2135
2136 # collect the current set of include-directories from compiler flags
2137 cf_header_path_list=""
2138 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2139         for cf_header_path in $CPPFLAGS $CFLAGS
2140         do
2141                 case "$cf_header_path" in
2142                 (-I*)
2143                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2144                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2145                         cf_header_path_list="$cf_header_path_list [$]$1"
2146                         ;;
2147                 esac
2148         done
2149 fi
2150
2151 # add the variations for the package we are looking for
2152 CF_SUBDIR_PATH($1,$2,include)
2153
2154 test "$includedir" != NONE && \
2155 test "$includedir" != "/usr/include" && \
2156 test -d "$includedir" && {
2157         test -d "$includedir" &&    $1="[$]$1 $includedir"
2158         test -d "$includedir/$2" && $1="[$]$1 $includedir/$2"
2159 }
2160
2161 test "$oldincludedir" != NONE && \
2162 test "$oldincludedir" != "/usr/include" && \
2163 test -d "$oldincludedir" && {
2164         test -d "$oldincludedir"    && $1="[$]$1 $oldincludedir"
2165         test -d "$oldincludedir/$2" && $1="[$]$1 $oldincludedir/$2"
2166 }
2167
2168 $1="[$]$1 $cf_header_path_list"
2169 ])dnl
2170 dnl ---------------------------------------------------------------------------
2171 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
2172 dnl ---------------
2173 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2174 AC_DEFUN([CF_HELP_MESSAGE],
2175 [CF_ACVERSION_CHECK(2.53,[],[
2176 AC_DIVERT_HELP($1)])dnl
2177 ])dnl
2178 dnl ---------------------------------------------------------------------------
2179 dnl CF_INHERIT_SCRIPT version: 2 updated: 2003/03/01 23:50:42
2180 dnl -----------------
2181 dnl If we do not have a given script, look for it in the parent directory.
2182 AC_DEFUN([CF_INHERIT_SCRIPT],
2183 [
2184 test -f $1 || ( test -f ../$1 && cp ../$1 ./ )
2185 ])dnl
2186 dnl ---------------------------------------------------------------------------
2187 dnl CF_INSTALL_OPTS version: 3 updated: 2023/06/03 15:17:30
2188 dnl ---------------
2189 dnl prompt for/fill-in useful install-program options
2190 AC_DEFUN([CF_INSTALL_OPTS],
2191 [
2192 CF_INSTALL_OPT_S
2193 CF_INSTALL_OPT_P
2194 CF_INSTALL_OPT_O
2195 CF_INSTALL_OPT_STRIP_PROG
2196 ])dnl
2197 dnl ---------------------------------------------------------------------------
2198 dnl CF_INSTALL_OPT_O version: 3 updated: 2020/12/31 20:19:42
2199 dnl ----------------
2200 dnl Almost all "install" programs default to the current user's ownership.
2201 dnl Almost - MINIX is an exception.
2202 AC_DEFUN([CF_INSTALL_OPT_O],
2203 [
2204 AC_MSG_CHECKING(if install needs to be told about ownership)
2205 case `$ac_config_guess` in
2206 (*minix)
2207         with_install_o=yes
2208         ;;
2209 (*)
2210         with_install_o=no
2211         ;;
2212 esac
2213
2214 AC_MSG_RESULT($with_install_o)
2215 if test "x$with_install_o" = xyes
2216 then
2217         INSTALL_OPT_O="`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`"
2218 else
2219         INSTALL_OPT_O=
2220 fi
2221
2222 AC_SUBST(INSTALL_OPT_O)
2223 ])dnl
2224 dnl ---------------------------------------------------------------------------
2225 dnl CF_INSTALL_OPT_P version: 3 updated: 2021/01/01 13:31:04
2226 dnl ----------------
2227 dnl Some install-programs accept a "-p" option to preserve file modification
2228 dnl timestamps.  That can be useful as an install option, as well as a way to
2229 dnl avoid the need for ranlib after copying a static archive.
2230 AC_DEFUN([CF_INSTALL_OPT_P],
2231 [
2232 : "${INSTALL:=install}"
2233 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
2234         rm -rf ./conftest*
2235         date >conftest.in
2236         mkdir conftest.out
2237         sleep 3
2238         if $INSTALL -p conftest.in conftest.out 2>/dev/null
2239         then
2240                 if test -f conftest.out/conftest.in
2241                 then
2242                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
2243                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
2244                         if test -s conftest.err
2245                         then
2246                                 cf_cv_install_p=no
2247                         else
2248                                 cf_cv_install_p=yes
2249                         fi
2250                 else
2251                         cf_cv_install_p=no
2252                 fi
2253         else
2254                 cf_cv_install_p=no
2255         fi
2256         rm -rf ./conftest*
2257 ])
2258 ])dnl
2259 dnl ---------------------------------------------------------------------------
2260 dnl CF_INSTALL_OPT_S version: 3 updated: 2021/01/05 19:23:48
2261 dnl ----------------
2262 dnl By default, we should strip executables which are installed, but leave the
2263 dnl ability to suppress that for unit-testing.
2264 AC_DEFUN([CF_INSTALL_OPT_S],
2265 [
2266 AC_MSG_CHECKING(if you want to install stripped executables)
2267 CF_ARG_DISABLE(stripping,
2268         [  --disable-stripping     do not strip (debug info) installed executables],
2269         [enable_stripping=no],
2270         [enable_stripping=yes])
2271 AC_MSG_RESULT($enable_stripping)
2272
2273 if test "$enable_stripping" = yes
2274 then
2275         INSTALL_OPT_S="-s"
2276 else
2277         INSTALL_OPT_S=
2278 fi
2279 AC_SUBST(INSTALL_OPT_S)
2280 ])dnl
2281 dnl ---------------------------------------------------------------------------
2282 dnl CF_INSTALL_OPT_STRIP_PROG version: 1 updated: 2023/06/03 15:17:30
2283 dnl -------------------------
2284 dnl Provide an option for overriding the strip program used in install "-s"
2285 dnl
2286 dnl coreutils install provides a --strip-program option
2287 dnl FreeBSD uses STRIPBIN environment variable, while NetBSD and OpenBSD use
2288 dnl STRIP environment variable.  Other versions of install do not support this.
2289 AC_DEFUN([CF_INSTALL_OPT_STRIP_PROG],
2290 [
2291 AC_REQUIRE([CF_INSTALL_OPT_S])
2292 if test -n "$INSTALL_OPT_S"
2293 then
2294         AC_MSG_CHECKING(if you want to specify strip-program)
2295         AC_ARG_WITH(strip-program,
2296                 [  --with-strip-program=XX specify program to use when stripping in install],
2297                 [with_strip_program=$withval],
2298                 [with_strip_program=no])
2299         AC_MSG_RESULT($with_strip_program)
2300         if test "$with_strip_program" != no
2301         then
2302                 AC_MSG_CHECKING(if strip-program is supported with this installer)
2303                 cf_install_program=`echo "$INSTALL" | sed -e 's%[[ ]]*[[ ]]-.%%'`
2304                 check_install_strip=no
2305                 if test -f "$cf_install_program"
2306                 then
2307                         check_install_version=`"$cf_install_program" --version 2>/dev/null | head -n 1 | grep coreutils`
2308                         if test -n "$check_install_version"
2309                         then
2310                                 check_install_strip="option"
2311                         else
2312                                 for check_strip_variable in STRIPBIN STRIP
2313                                 do
2314                                         if strings "$cf_install_program" | grep "^$check_strip_variable[$]" >/dev/null
2315                                         then
2316                                                 check_install_strip="environ"
2317                                                 break
2318                                         fi
2319                                 done
2320                         fi
2321                 fi
2322                 AC_MSG_RESULT($check_install_strip)
2323                 case "$check_install_strip" in
2324                 (no)
2325                         AC_MSG_WARN($cf_install_program does not support strip program option)
2326                         with_strip_program=no
2327                         ;;
2328                 (environ)
2329                         cat >install.tmp <<-CF_EOF
2330                         #! $SHELL
2331                         STRIPBIN="$with_strip_program" \\
2332                         STRIP="$with_strip_program" \\
2333                         $INSTALL "[$]@"
2334                         CF_EOF
2335                         INSTALL="`pwd`/install.tmp"
2336                         chmod +x "$INSTALL"
2337                         CF_VERBOSE(created $INSTALL)
2338                         ;;
2339                 (option)
2340                         INSTALL_OPT_S="$INSTALL_OPT_S --strip-program=\"$with_strip_program\""
2341                         ;;
2342                 esac
2343         fi
2344 fi
2345 AC_SUBST(INSTALL_OPT_S)
2346 ])dnl
2347 dnl ---------------------------------------------------------------------------
2348 dnl CF_INTEL_COMPILER version: 9 updated: 2023/02/18 17:41:25
2349 dnl -----------------
2350 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2351 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2352 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2353 dnl
2354 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2355 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2356 dnl the wrappers for gcc and g++ warnings.
2357 dnl
2358 dnl $1 = GCC (default) or GXX
2359 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2360 dnl $3 = CFLAGS (default) or CXXFLAGS
2361 AC_DEFUN([CF_INTEL_COMPILER],[
2362 AC_REQUIRE([AC_CANONICAL_HOST])
2363 ifelse([$2],,INTEL_COMPILER,[$2])=no
2364
2365 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2366         case "$host_os" in
2367         (linux*|gnu*)
2368                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2369                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2370                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2371                 AC_TRY_COMPILE([],[
2372 #ifdef __INTEL_COMPILER
2373 #else
2374 #error __INTEL_COMPILER is not defined
2375 #endif
2376 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2377 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
2378 ],[])
2379                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2380                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2381                 ;;
2382         esac
2383 fi
2384 ])dnl
2385 dnl ---------------------------------------------------------------------------
2386 dnl CF_LD_RPATH_OPT version: 9 updated: 2021/01/01 13:31:04
2387 dnl ---------------
2388 dnl For the given system and compiler, find the compiler flags to pass to the
2389 dnl loader to use the "rpath" feature.
2390 AC_DEFUN([CF_LD_RPATH_OPT],
2391 [
2392 AC_REQUIRE([CF_CHECK_CACHE])
2393
2394 LD_RPATH_OPT=
2395 if test "x$cf_cv_enable_rpath" != xno
2396 then
2397         AC_MSG_CHECKING(for an rpath option)
2398         case "$cf_cv_system_name" in
2399         (irix*)
2400                 if test "$GCC" = yes; then
2401                         LD_RPATH_OPT="-Wl,-rpath,"
2402                 else
2403                         LD_RPATH_OPT="-rpath "
2404                 fi
2405                 ;;
2406         (linux*|gnu*|k*bsd*-gnu|freebsd*)
2407                 LD_RPATH_OPT="-Wl,-rpath,"
2408                 ;;
2409         (openbsd[[2-9]].*|mirbsd*)
2410                 LD_RPATH_OPT="-Wl,-rpath,"
2411                 ;;
2412         (dragonfly*)
2413                 LD_RPATH_OPT="-rpath "
2414                 ;;
2415         (netbsd*)
2416                 LD_RPATH_OPT="-Wl,-rpath,"
2417                 ;;
2418         (osf*|mls+*)
2419                 LD_RPATH_OPT="-rpath "
2420                 ;;
2421         (solaris2*)
2422                 LD_RPATH_OPT="-R"
2423                 ;;
2424         (*)
2425                 ;;
2426         esac
2427         AC_MSG_RESULT($LD_RPATH_OPT)
2428
2429         case "x$LD_RPATH_OPT" in
2430         (x-R*)
2431                 AC_MSG_CHECKING(if we need a space after rpath option)
2432                 cf_save_LIBS="$LIBS"
2433                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
2434                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
2435                 LIBS="$cf_save_LIBS"
2436                 AC_MSG_RESULT($cf_rpath_space)
2437                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
2438                 ;;
2439         esac
2440 fi
2441 ])dnl
2442 dnl ---------------------------------------------------------------------------
2443 dnl CF_LIBRARY_PATH version: 11 updated: 2021/01/01 13:31:04
2444 dnl ---------------
2445 dnl Construct a search-list of directories for a nonstandard library-file
2446 dnl
2447 dnl Parameters
2448 dnl     $1 = the variable to return as result
2449 dnl     $2 = the package name
2450 AC_DEFUN([CF_LIBRARY_PATH],
2451 [
2452 $1=
2453 cf_library_path_list=""
2454 if test -n "${LDFLAGS}${LIBS}" ; then
2455         for cf_library_path in $LDFLAGS $LIBS
2456         do
2457                 case "$cf_library_path" in
2458                 (-L*)
2459                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
2460                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
2461                         cf_library_path_list="$cf_library_path_list [$]$1"
2462                         ;;
2463                 esac
2464         done
2465 fi
2466
2467 CF_SUBDIR_PATH($1,$2,lib)
2468
2469 $1="$cf_library_path_list [$]$1"
2470 ])dnl
2471 dnl ---------------------------------------------------------------------------
2472 dnl CF_MAKE_PHONY version: 3 updated: 2021/01/08 16:08:21
2473 dnl -------------
2474 dnl Check if the make-program handles a ".PHONY" target, e.g,. a target which
2475 dnl acts as a placeholder.
2476 dnl
2477 dnl The ".PHONY" feature was proposed in 2011 here
2478 dnl     https://www.austingroupbugs.net/view.php?id=523
2479 dnl and is scheduled for release in P1003.1 Issue 8 (late 2022).
2480 dnl
2481 dnl This is not supported by SVr4 make (or SunOS 4, 4.3SD, etc), but works with
2482 dnl a few others (i.e., GNU make and the non-POSIX "BSD" make):
2483 dnl
2484 dnl + This is a GNU make feature (since April 1988, but in turn from binutils,
2485 dnl   date unspecified).
2486 dnl
2487 dnl + It was adopted in NetBSD make in June 1995.
2488 dnl
2489 dnl + The other BSD make programs are derived from the NetBSD make (and for
2490 dnl   that reason are not actually different "implementations").
2491 dnl
2492 dnl + Some features of NetBSD make were actually adapted from pmake, which
2493 dnl   began as a modified GNU make starting in 1993.
2494 dnl
2495 dnl + Version 3.8 of the dmake program in January 1992 also implemented this
2496 dnl   GNU make extension, but is less well known than the BSD make.
2497 AC_DEFUN([CF_MAKE_PHONY],[
2498 AC_CACHE_CHECK(for \".PHONY\" make-support, cf_cv_make_PHONY,[
2499         rm -rf conftest*
2500         (
2501                 mkdir conftest || exit 1
2502                 cd conftest
2503                 cat >makefile <<'CF_EOF'
2504 .PHONY: always
2505 DATA=0
2506 always: always.out
2507         @echo "** making [$]@ [$](DATA)"
2508 once: once.out
2509         @echo "** making [$]@ [$](DATA)"
2510 always.out:
2511         @echo "** making [$]@ [$](DATA)"
2512         echo [$](DATA) > [$]@
2513 once.out:
2514         @echo "** making [$]@ [$](DATA)"
2515         echo [$](DATA) > [$]@
2516 CF_EOF
2517                 for cf_data in 1 2 3
2518                 do
2519                         ${MAKE:-make} always DATA=$cf_data
2520                         ${MAKE:-make} once   DATA=$cf_data
2521                         ${MAKE:-make} -t always once
2522                         if test -f always ; then
2523                                 echo "no (case 1)" > ../conftest.tmp
2524                         elif test ! -f always.out ; then
2525                                 echo "no (case 2)" > ../conftest.tmp
2526                         elif test ! -f once.out ; then
2527                                 echo "no (case 3)" > ../conftest.tmp
2528                         elif ! cmp -s always.out once.out ; then
2529                                 echo "no (case 4)" > ../conftest.tmp
2530                                 diff always.out once.out
2531                         else
2532                                 cf_check="`cat always.out`"
2533                                 if test "x$cf_check" != "x$cf_data" ; then
2534                                         echo "no (case 5)" > ../conftest.tmp
2535                                 else
2536                                         echo yes > ../conftest.tmp
2537                                         rm -f ./*.out
2538                                         continue
2539                                 fi
2540                         fi
2541                         break
2542                 done
2543         ) >&AC_FD_CC 2>&1
2544         cf_cv_make_PHONY="`cat conftest.tmp`"
2545         rm -rf conftest*
2546 ])
2547 MAKE_NO_PHONY="#"
2548 MAKE_PHONY="#"
2549 test "x$cf_cv_make_PHONY" = xyes && MAKE_PHONY=
2550 test "x$cf_cv_make_PHONY" != xyes && MAKE_NO_PHONY=
2551 AC_SUBST(MAKE_NO_PHONY)
2552 AC_SUBST(MAKE_PHONY)
2553 ])dnl
2554 dnl ---------------------------------------------------------------------------
2555 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
2556 dnl ------------
2557 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
2558 dnl a monocase filesystem.
2559 AC_DEFUN([CF_MAKE_TAGS],[
2560 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
2561
2562 AC_CHECK_PROGS(CTAGS, exctags ctags)
2563 AC_CHECK_PROGS(ETAGS, exetags etags)
2564
2565 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
2566
2567 if test "$cf_cv_mixedcase" = yes ; then
2568         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
2569 else
2570         MAKE_UPPER_TAGS=no
2571 fi
2572
2573 if test "$MAKE_UPPER_TAGS" = yes ; then
2574         MAKE_UPPER_TAGS=
2575 else
2576         MAKE_UPPER_TAGS="#"
2577 fi
2578
2579 if test "$MAKE_LOWER_TAGS" = yes ; then
2580         MAKE_LOWER_TAGS=
2581 else
2582         MAKE_LOWER_TAGS="#"
2583 fi
2584
2585 AC_SUBST(CTAGS)
2586 AC_SUBST(ETAGS)
2587
2588 AC_SUBST(MAKE_UPPER_TAGS)
2589 AC_SUBST(MAKE_LOWER_TAGS)
2590 ])dnl
2591 dnl ---------------------------------------------------------------------------
2592 dnl CF_MATH_LIB version: 11 updated: 2022/07/27 19:01:48
2593 dnl -----------
2594 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
2595 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
2596 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
2597 AC_DEFUN([CF_MATH_LIB],
2598 [
2599 AC_CACHE_CHECK(if -lm needed for math functions,
2600         cf_cv_need_libm,[
2601         AC_TRY_LINK([
2602                 #include <stdio.h>
2603                 #include <stdlib.h>
2604                 #include <math.h>
2605         ],
2606         [double x = rand(); printf("result = %g\\n", ]ifelse([$2],,sin(x),$2)[)],
2607         [cf_cv_need_libm=no],
2608         [cf_cv_need_libm=yes])])
2609
2610 if test "$cf_cv_need_libm" = yes
2611 then
2612
2613         cf_save_LIBS="$LIBS"
2614         LIBS="$LIBS -lm"
2615         AC_CACHE_CHECK(if -lm is available for math functions,
2616         cf_cv_have_libm,[
2617         AC_TRY_LINK([
2618                 #include <stdio.h>
2619                 #include <stdlib.h>
2620                 #include <math.h>
2621         ],
2622         [double x = rand(); printf("result = %g\\n", ]ifelse([$2],,sin(x),$2)[)],
2623         [cf_cv_have_libm=yes],
2624         [cf_cv_have_libm=no])])
2625         LIBS="$cf_save_LIBS"
2626
2627         if test "$cf_cv_have_libm" = yes
2628         then
2629                 ifelse($1,,[CF_ADD_LIB(m)],[$1=-lm])
2630         fi
2631 else
2632         cf_cv_have_libm=yes
2633 fi
2634
2635 if test "$cf_cv_have_libm" = yes
2636 then
2637         AC_DEFINE(HAVE_MATH_FUNCS,1,[Define to 1 if math functions are available])
2638 fi
2639 ])
2640 dnl ---------------------------------------------------------------------------
2641 dnl CF_MIXEDCASE_FILENAMES version: 9 updated: 2021/01/01 16:53:59
2642 dnl ----------------------
2643 dnl Check if the file-system supports mixed-case filenames.  If we're able to
2644 dnl create a lowercase name and see it as uppercase, it doesn't support that.
2645 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
2646 [
2647 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2648 if test "$cross_compiling" = yes ; then
2649         case "$target_alias" in
2650         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*|darwin*)
2651                 cf_cv_mixedcase=no
2652                 ;;
2653         (*)
2654                 cf_cv_mixedcase=yes
2655                 ;;
2656         esac
2657 else
2658         rm -f conftest CONFTEST
2659         echo test >conftest
2660         if test -f CONFTEST ; then
2661                 cf_cv_mixedcase=no
2662         else
2663                 cf_cv_mixedcase=yes
2664         fi
2665         rm -f conftest CONFTEST
2666 fi
2667 ])
2668 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2669 ])dnl
2670 dnl ---------------------------------------------------------------------------
2671 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2672 dnl ----------
2673 dnl Write a debug message to config.log, along with the line number in the
2674 dnl configure script.
2675 AC_DEFUN([CF_MSG_LOG],[
2676 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2677 ])dnl
2678 dnl ---------------------------------------------------------------------------
2679 dnl CF_NCURSES_CC_CHECK version: 6 updated: 2023/02/18 17:47:58
2680 dnl -------------------
2681 dnl Check if we can compile with ncurses' header file
2682 dnl $1 is the cache variable to set
2683 dnl $2 is the header-file to include
2684 dnl $3 is the root name (ncurses or ncursesw)
2685 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2686         AC_TRY_COMPILE([
2687 ]ifelse($3,ncursesw,[
2688 #define _XOPEN_SOURCE_EXTENDED
2689 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2690 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2691 ])[
2692 #include <$2>],[
2693 #ifdef NCURSES_VERSION
2694 ]ifelse($3,ncursesw,[
2695 #ifndef WACS_BSSB
2696         #error WACS_BSSB is not defined
2697 #endif
2698 ])[
2699 printf("%s\\n", NCURSES_VERSION);
2700 #else
2701 #ifdef __NCURSES_H
2702 printf("old\\n");
2703 #else
2704         #error __NCURSES_H is not defined
2705 #endif
2706 #endif
2707         ]
2708         ,[$1=$2]
2709         ,[$1=no])
2710 ])dnl
2711 dnl ---------------------------------------------------------------------------
2712 dnl CF_NCURSES_CONFIG version: 28 updated: 2021/08/28 15:20:37
2713 dnl -----------------
2714 dnl Tie together the configure-script macros for ncurses, preferring these in
2715 dnl order:
2716 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2717 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2718 dnl c) just plain libraries
2719 dnl
2720 dnl $1 is the root library name (default: "ncurses")
2721 AC_DEFUN([CF_NCURSES_CONFIG],[
2722 AC_REQUIRE([CF_PKG_CONFIG])
2723 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2724 cf_have_ncuconfig=no
2725
2726 if test "x${PKG_CONFIG:=none}" != xnone; then
2727         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2728         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2729                 AC_MSG_RESULT(yes)
2730
2731                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2732                 cf_have_ncuconfig=unknown
2733
2734                 cf_save_CFLAGS="$CFLAGS"
2735                 cf_save_CPPFLAGS="$CPPFLAGS"
2736                 cf_save_LIBS="$LIBS"
2737
2738                 cf_pkg_cflags="`$PKG_CONFIG --cflags $cf_ncuconfig_root`"
2739                 cf_pkg_libs="`$PKG_CONFIG --libs $cf_ncuconfig_root`"
2740
2741                 # while -W for passing linker flags is prevalent, it is not "standard".
2742                 # At least one wrapper for c89/c99 (in Apple's xcode) has its own
2743                 # incompatible _and_ non-standard -W option which gives an error.  Work
2744                 # around that pitfall.
2745                 case "x${CC}@@${cf_pkg_libs}@${cf_pkg_cflags}" in
2746                 (x*c[[89]]9@@*-W*)
2747                         CF_ADD_CFLAGS($cf_pkg_cflags)
2748                         CF_ADD_LIBS($cf_pkg_libs)
2749
2750                         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2751                                 [initscr(); mousemask(0,0); tigetstr((char *)0);],
2752                                 [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2753                                         int main(void)
2754                                         { const char *xx = curses_version(); return (xx == 0); }],
2755                                         [cf_test_ncuconfig=yes],
2756                                         [cf_test_ncuconfig=no],
2757                                         [cf_test_ncuconfig=maybe])],
2758                                 [cf_test_ncuconfig=no])
2759
2760                         CFLAGS="$cf_save_CFLAGS"
2761                         CPPFLAGS="$cf_save_CPPFLAGS"
2762                         LIBS="$cf_save_LIBS"
2763
2764                         if test "x$cf_test_ncuconfig" != xyes; then
2765                                 cf_temp=`echo "x$cf_pkg_cflags" | sed -e s/^x// -e 's/-W[[^     ]]*//g'`
2766                                 cf_pkg_cflags="$cf_temp"
2767                                 cf_temp=`echo "x$cf_pkg_libs" | sed -e s/^x// -e 's/-W[[^       ]]*//g'`
2768                                 cf_pkg_libs="$cf_temp"
2769                         fi
2770                         ;;
2771                 esac
2772
2773                 CF_APPEND_CFLAGS($cf_pkg_cflags)
2774                 CF_ADD_LIBS($cf_pkg_libs)
2775
2776                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2777                         [initscr(); mousemask(0,0); tigetstr((char *)0);],
2778                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2779                                 int main(void)
2780                                 { const char *xx = curses_version(); return (xx == 0); }],
2781                                 [cf_have_ncuconfig=yes],
2782                                 [cf_have_ncuconfig=no],
2783                                 [cf_have_ncuconfig=maybe])],
2784                         [cf_have_ncuconfig=no])
2785                 AC_MSG_RESULT($cf_have_ncuconfig)
2786                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
2787                 if test "$cf_have_ncuconfig" != "yes"
2788                 then
2789                         CPPFLAGS="$cf_save_CPPFLAGS"
2790                         LIBS="$cf_save_LIBS"
2791                         NCURSES_CONFIG_PKG=none
2792                 else
2793                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2794                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2795                         CF_TERM_HEADER
2796                 fi
2797
2798         else
2799                 AC_MSG_RESULT(no)
2800                 NCURSES_CONFIG_PKG=none
2801         fi
2802 else
2803         NCURSES_CONFIG_PKG=none
2804 fi
2805
2806 if test "x$cf_have_ncuconfig" = "xno"; then
2807         cf_ncurses_config="${cf_ncuconfig_root}${NCURSES_CONFIG_SUFFIX}-config"; echo "Looking for ${cf_ncurses_config}"
2808
2809         CF_ACVERSION_CHECK(2.52,
2810                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2811                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2812
2813         if test "$NCURSES_CONFIG" != none ; then
2814
2815                 CF_APPEND_CFLAGS(`$NCURSES_CONFIG --cflags`)
2816                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2817
2818                 # even with config script, some packages use no-override for curses.h
2819                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2820
2821                 dnl like CF_NCURSES_CPPFLAGS
2822                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2823
2824                 dnl like CF_NCURSES_LIBS
2825                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2826                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2827
2828                 dnl like CF_NCURSES_VERSION
2829                 cf_cv_ncurses_version="`$NCURSES_CONFIG --version`"
2830
2831         else
2832
2833                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2834                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2835
2836         fi
2837 else
2838         NCURSES_CONFIG=none
2839 fi
2840 ])dnl
2841 dnl ---------------------------------------------------------------------------
2842 dnl CF_NCURSES_CPPFLAGS version: 22 updated: 2021/01/02 09:31:20
2843 dnl -------------------
2844 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2845 dnl the CPPFLAGS variable so we can include its header.
2846 dnl
2847 dnl The header files may be installed as either curses.h, or ncurses.h (would
2848 dnl be obsolete, except that some packagers prefer this name to distinguish it
2849 dnl from a "native" curses implementation).  If not installed for overwrite,
2850 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2851 dnl /usr/include/ncurses), but someone may have installed overwriting the
2852 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2853 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2854 dnl the header.
2855 dnl
2856 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2857 dnl is already in the include-path, don't even bother with this, since we cannot
2858 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2859 dnl
2860 dnl The optional parameter gives the root name of the library, in case it is
2861 dnl not installed as the default curses library.  That is how the
2862 dnl wide-character version of ncurses is installed.
2863 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2864 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2865
2866 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2867 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2868
2869 test -n "$cf_cv_curses_dir" && \
2870 test "$cf_cv_curses_dir" != "no" && { \
2871   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2872 }
2873
2874 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2875         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2876         { test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw; } && cf_header_list="$cf_header_list curses.h ncurses.h"
2877         for cf_header in $cf_header_list
2878         do
2879                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2880                 test "$cf_cv_ncurses_h" != no && break
2881         done
2882 ])
2883
2884 CF_NCURSES_HEADER
2885 CF_TERM_HEADER
2886
2887 # some applications need this, but should check for NCURSES_VERSION
2888 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2889
2890 CF_NCURSES_VERSION
2891 ])dnl
2892 dnl ---------------------------------------------------------------------------
2893 dnl CF_NCURSES_EXT_FUNCS version: 4 updated: 2012/10/06 16:39:58
2894 dnl --------------------
2895 dnl Since 2007/11/17, ncurses has defined NCURSES_EXT_FUNCS; earlier versions
2896 dnl may provide these functions.  Define the symbol if it is not defined, and
2897 dnl if it is valid.
2898 AC_DEFUN([CF_NCURSES_EXT_FUNCS],
2899 [
2900 AC_CACHE_CHECK(for ncurses extended functions,cf_cv_ncurses_ext_funcs,[
2901 AC_TRY_COMPILE([
2902 #include <${cf_cv_ncurses_header:-curses.h}>],
2903 [
2904 int x = NCURSES_EXT_FUNCS
2905 ],[cf_cv_ncurses_ext_funcs=defined],[
2906 AC_TRY_LINK([
2907 #include <${cf_cv_ncurses_header:-curses.h}>],
2908 [
2909         (void) assume_default_colors (0, 0);
2910         (void) curses_version ();
2911         (void) define_key (0, 0);
2912         (void) is_term_resized (0, 0);
2913         (void) key_defined (0);
2914         (void) keybound (0, 0);
2915         (void) keyok (0, 0);
2916         (void) resize_term (0, 0);
2917         (void) resizeterm (0, 0);
2918         (void) use_default_colors ();
2919         (void) use_extended_names (0);
2920         (void) wresize (0, 0, 0);],
2921         [cf_cv_ncurses_ext_funcs=yes],
2922         [cf_cv_ncurses_ext_funcs=no])
2923 ])
2924 ])
2925 test "$cf_cv_ncurses_ext_funcs" = yes && AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 if we have ncurses extensions])
2926 ])dnl
2927 dnl ---------------------------------------------------------------------------
2928 dnl CF_NCURSES_HEADER version: 7 updated: 2021/01/04 19:33:05
2929 dnl -----------------
2930 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2931 dnl variations of ncurses' installs.
2932 dnl
2933 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2934 AC_DEFUN([CF_NCURSES_HEADER],[
2935
2936 if test "$cf_cv_ncurses_h" != no ; then
2937         cf_cv_ncurses_header=$cf_cv_ncurses_h
2938 else
2939
2940 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2941         test -n "$verbose" && echo
2942         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2943         test -n "$verbose" && echo "search path $cf_search"
2944         cf_save2_CPPFLAGS="$CPPFLAGS"
2945         for cf_incdir in $cf_search
2946         do
2947                 CF_ADD_INCDIR($cf_incdir)
2948                 for cf_header in \
2949                         ncurses.h \
2950                         curses.h
2951                 do
2952                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2953                         if test "$cf_cv_ncurses_h2" != no ; then
2954                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2955                                 test -n "$verbose" && echo $ECHO_N "    ... found $ECHO_C" 1>&AC_FD_MSG
2956                                 break
2957                         fi
2958                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2959                 done
2960                 CPPFLAGS="$cf_save2_CPPFLAGS"
2961                 test "$cf_cv_ncurses_h2" != no && break
2962         done
2963         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2964         ])
2965
2966         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2967         cf_cv_ncurses_header="`basename "$cf_cv_ncurses_h2"`"
2968         if test "`basename "$cf_1st_incdir"`" = "$cf_ncuhdr_root" ; then
2969                 cf_cv_ncurses_header="$cf_ncuhdr_root/$cf_cv_ncurses_header"
2970         fi
2971         CF_ADD_INCDIR($cf_1st_incdir)
2972
2973 fi
2974
2975 # Set definitions to allow ifdef'ing for ncurses.h
2976
2977 case "$cf_cv_ncurses_header" in
2978 (*ncurses.h)
2979         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2980         ;;
2981 esac
2982
2983 case "$cf_cv_ncurses_header" in
2984 (ncurses/curses.h|ncurses/ncurses.h)
2985         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2986         ;;
2987 (ncursesw/curses.h|ncursesw/ncurses.h)
2988         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2989         ;;
2990 esac
2991
2992 ])dnl
2993 dnl ---------------------------------------------------------------------------
2994 dnl CF_NCURSES_LIBS version: 21 updated: 2021/09/04 06:37:12
2995 dnl ---------------
2996 dnl Look for the ncurses library.  This is a little complicated on Linux,
2997 dnl because it may be linked with the gpm (general purpose mouse) library.
2998 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2999 dnl unusable with ncurses.  However, we don't want to link with gpm unless
3000 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
3001 dnl and the linker will record a dependency.
3002 dnl
3003 dnl The optional parameter gives the root name of the library, in case it is
3004 dnl not installed as the default curses library.  That is how the
3005 dnl wide-character version of ncurses is installed.
3006 AC_DEFUN([CF_NCURSES_LIBS],
3007 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
3008
3009 cf_nculib_root=ifelse($1,,ncurses,$1)
3010         # This works, except for the special case where we find gpm, but
3011         # ncurses is in a nonstandard location via $LIBS, and we really want
3012         # to link gpm.
3013 cf_ncurses_LIBS=""
3014 cf_ncurses_SAVE="$LIBS"
3015 AC_CHECK_LIB(gpm,Gpm_Open,
3016         [AC_CHECK_LIB(gpm,initscr,
3017                 [LIBS="$cf_ncurses_SAVE"],
3018                 [cf_ncurses_LIBS="-lgpm"])])
3019
3020 case "$host_os" in
3021 (freebsd*)
3022         # This is only necessary if you are linking against an obsolete
3023         # version of ncurses (but it should do no harm, since it is static).
3024         if test "$cf_nculib_root" = ncurses ; then
3025                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
3026         fi
3027         ;;
3028 esac
3029
3030 CF_ADD_LIBS($cf_ncurses_LIBS)
3031
3032 if test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no"
3033 then
3034         CF_ADD_LIBS(-l$cf_nculib_root)
3035 else
3036         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
3037                 [#include <${cf_cv_ncurses_header:-curses.h}>],
3038                 [initscr()],
3039                 initscr)
3040 fi
3041
3042 if test -n "$cf_ncurses_LIBS" ; then
3043         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
3044         cf_ncurses_SAVE="$LIBS"
3045         for p in $cf_ncurses_LIBS ; do
3046                 q=`echo "$LIBS" | sed -e "s%$p %%" -e "s%$p$%%"`
3047                 if test "$q" != "$LIBS" ; then
3048                         LIBS="$q"
3049                 fi
3050         done
3051         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
3052                 [initscr(); mousemask(0,0); tigetstr((char *)0);],
3053                 [AC_MSG_RESULT(yes)],
3054                 [AC_MSG_RESULT(no)
3055                  LIBS="$cf_ncurses_SAVE"])
3056 fi
3057
3058 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
3059 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
3060 ])dnl
3061 dnl ---------------------------------------------------------------------------
3062 dnl CF_NCURSES_PTHREADS version: 2 updated: 2016/04/22 05:07:41
3063 dnl -------------------
3064 dnl Use this followup check to ensure that we link with pthreads if ncurses
3065 dnl uses it.
3066 AC_DEFUN([CF_NCURSES_PTHREADS],[
3067 : ${cf_nculib_root:=ifelse($1,,ncurses,$1)}
3068 AC_CHECK_LIB($cf_nculib_root,_nc_init_pthreads,
3069         cf_cv_ncurses_pthreads=yes,
3070         cf_cv_ncurses_pthreads=no)
3071 if test "$cf_cv_ncurses_pthreads" = yes
3072 then
3073         CF_ADD_LIBS(-lpthread)
3074 fi
3075 ])dnl
3076 dnl ---------------------------------------------------------------------------
3077 dnl CF_NCURSES_VERSION version: 18 updated: 2024/01/07 06:34:16
3078 dnl ------------------
3079 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
3080 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
3081 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
3082 AC_DEFUN([CF_NCURSES_VERSION],
3083 [
3084 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
3085 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
3086         cf_cv_ncurses_version=no
3087         cf_tempfile=out$$
3088         rm -f "$cf_tempfile"
3089         AC_TRY_RUN([
3090 $ac_includes_default
3091
3092 #include <${cf_cv_ncurses_header:-curses.h}>
3093
3094 int main(void)
3095 {
3096         FILE *fp = fopen("$cf_tempfile", "w");
3097 #ifdef NCURSES_VERSION
3098 # ifdef NCURSES_VERSION_PATCH
3099         fprintf(fp, "%s.%d\\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
3100 # else
3101         fprintf(fp, "%s\\n", NCURSES_VERSION);
3102 # endif
3103 #else
3104 # ifdef __NCURSES_H
3105         fprintf(fp, "old\\n");
3106 # else
3107         #error expected ncurses header to define __NCURSES_H
3108 # endif
3109 #endif
3110         ${cf_cv_main_return:-return}(0);
3111 }],[
3112         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
3113
3114         # This will not work if the preprocessor splits the line after the
3115         # Autoconf token.  The 'unproto' program does that.
3116         cat > "conftest.$ac_ext" <<EOF
3117 #include <${cf_cv_ncurses_header:-curses.h}>
3118 #undef Autoconf
3119 #ifdef NCURSES_VERSION
3120 Autoconf NCURSES_VERSION
3121 #else
3122 #ifdef __NCURSES_H
3123 Autoconf "old"
3124 #endif
3125 ;
3126 #endif
3127 EOF
3128         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
3129         AC_TRY_EVAL(cf_try)
3130         if test -f conftest.out ; then
3131                 cf_out=`sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%' conftest.out`
3132                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
3133                 rm -f conftest.out
3134         fi
3135 ])
3136         rm -f "$cf_tempfile"
3137 ])
3138 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
3139 ])dnl
3140 dnl ---------------------------------------------------------------------------
3141 dnl CF_NCURSES_WRAP_PREFIX version: 1 updated: 2009/03/28 16:08:10
3142 dnl ----------------------
3143 dnl Check for ncurses "wrap-prefix" used for public variables which have been
3144 dnl wrapped with a function to help with concurrency control.
3145 AC_DEFUN([CF_NCURSES_WRAP_PREFIX],
3146 [
3147 AC_MSG_CHECKING(for ncurses wrap-prefix)
3148 AC_ARG_WITH(ncurses-wrap-prefix,
3149         [  --with-ncurses-wrap-prefix naming-prefix for ncurses wrapped-variables],
3150         [NCURSES_WRAP_PREFIX=$withval],
3151         [NCURSES_WRAP_PREFIX=_nc_])
3152 AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
3153
3154 AC_SUBST(NCURSES_WRAP_PREFIX)
3155 ])
3156 dnl ---------------------------------------------------------------------------
3157 dnl CF_NETBSD_FORM_H version: 2 updated: 2012/10/06 16:39:58
3158 dnl ----------------
3159 dnl Check for NetBSD's form.h, which is incompatible with SVr4 and ncurses.
3160 dnl Some workarounds are needed in client programs to allow them to compile.
3161 AC_DEFUN([CF_NETBSD_FORM_H],[
3162 AC_CACHE_CHECK(for NetBSD form.h,cf_cv_netbsd_form_h,[
3163 AC_TRY_COMPILE([
3164 #include <${cf_cv_ncurses_header:-curses.h}>
3165 #include <form.h>
3166 ],[
3167         FORM *form;
3168         int y = current_field(form)->cursor_ypos;
3169         int x = current_field(form)->cursor_xpos;
3170 ],[cf_cv_netbsd_form_h=yes
3171 ],[cf_cv_netbsd_form_h=no])
3172 ])
3173
3174 test "$cf_cv_netbsd_form_h" = yes && AC_DEFINE(HAVE_NETBSD_FORM_H,1,[Define to 1 if we appear to be using NetBSD form.h])
3175 ])dnl
3176 dnl ---------------------------------------------------------------------------
3177 dnl CF_NETBSD_MENU_H version: 2 updated: 2012/10/06 16:39:58
3178 dnl ----------------
3179 dnl Check for NetBSD's menu.h, which is incompatible with SVr4 and ncurses.
3180 dnl Some workarounds are needed in client programs to allow them to compile.
3181 AC_DEFUN([CF_NETBSD_MENU_H],[
3182 AC_CACHE_CHECK(for NetBSD menu.h,cf_cv_netbsd_menu_h,[
3183 AC_TRY_COMPILE([
3184 #include <${cf_cv_ncurses_header:-curses.h}>
3185 #include <menu.h>
3186 ],[
3187         MENU *menu;
3188         int y = menu->max_item_width;
3189 ],[cf_cv_netbsd_menu_h=yes
3190 ],[cf_cv_netbsd_menu_h=no])
3191 ])
3192
3193 test "$cf_cv_netbsd_menu_h" = yes && AC_DEFINE(HAVE_NETBSD_MENU_H,1,[Define to 1 if we appear to be using NetBSD menu.h])
3194 ])dnl
3195 dnl ---------------------------------------------------------------------------
3196 dnl CF_NO_LEAKS_OPTION version: 9 updated: 2021/06/13 19:45:41
3197 dnl ------------------
3198 dnl see CF_WITH_NO_LEAKS
3199 dnl
3200 dnl $1 = option/name
3201 dnl $2 = help-text
3202 dnl $3 = symbol to define if the option is set
3203 dnl $4 = additional actions to take if the option is set
3204 AC_DEFUN([CF_NO_LEAKS_OPTION],[
3205 AC_MSG_CHECKING(if you want to use $1 for testing)
3206 AC_ARG_WITH($1,
3207         [$2],
3208         [case "x$withval" in
3209         (x|xno) ;;
3210         (*)
3211                 : "${with_cflags:=-g}"
3212                 : "${enable_leaks:=no}"
3213                 with_$1=yes
3214                 AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
3215          $4
3216 ])
3217                 ;;
3218         esac],
3219         [with_$1=])
3220 AC_MSG_RESULT(${with_$1:-no})
3221
3222 case ".$with_cflags" in
3223 (.*-g*)
3224         case .$CFLAGS in
3225         (.*-g*)
3226                 ;;
3227         (*)
3228                 CF_ADD_CFLAGS([-g])
3229                 ;;
3230         esac
3231         ;;
3232 esac
3233 ])dnl
3234 dnl ---------------------------------------------------------------------------
3235 dnl CF_PATH_SYNTAX version: 18 updated: 2020/12/31 18:40:20
3236 dnl --------------
3237 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
3238 dnl begins with one of the prefix/exec_prefix variables, and then again if the
3239 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
3240 dnl delayed evaluation of those symbols.
3241 AC_DEFUN([CF_PATH_SYNTAX],[
3242 if test "x$prefix" != xNONE; then
3243         cf_path_syntax="$prefix"
3244 else
3245         cf_path_syntax="$ac_default_prefix"
3246 fi
3247
3248 case ".[$]$1" in
3249 (.\[$]\(*\)*|.\'*\'*)
3250         ;;
3251 (..|./*|.\\*)
3252         ;;
3253 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
3254         ;;
3255 (.\[$]\{*prefix\}*|.\[$]\{*dir\}*)
3256         eval $1="[$]$1"
3257         case ".[$]$1" in
3258         (.NONE/*)
3259                 $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
3260                 ;;
3261         esac
3262         ;;
3263 (.no|.NONE/*)
3264         $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
3265         ;;
3266 (*)
3267         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
3268         ;;
3269 esac
3270 ])dnl
3271 dnl ---------------------------------------------------------------------------
3272 dnl CF_PDCURSES_X11 version: 15 updated: 2021/01/02 09:31:20
3273 dnl ---------------
3274 dnl Configure for PDCurses' X11 library
3275 AC_DEFUN([CF_PDCURSES_X11],[
3276 AC_REQUIRE([CF_X_ATHENA])
3277
3278 CF_ACVERSION_CHECK(2.52,
3279         [AC_CHECK_TOOLS(XCURSES_CONFIG, xcurses-config, none)],
3280         [AC_PATH_PROGS(XCURSES_CONFIG, xcurses-config, none)])
3281
3282 if test "$XCURSES_CONFIG" != none ; then
3283
3284 CF_ADD_CFLAGS(`$XCURSES_CONFIG --cflags`)
3285 CF_ADD_LIBS(`$XCURSES_CONFIG --libs`)
3286
3287 cf_cv_lib_XCurses=yes
3288
3289 else
3290
3291 LDFLAGS="$LDFLAGS $X_LIBS"
3292 CF_CHECK_CFLAGS($X_CFLAGS)
3293 AC_CHECK_LIB(X11,XOpenDisplay,
3294         [CF_ADD_LIBS(-lX11)],,
3295         [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])
3296 AC_CACHE_CHECK(for XCurses library,cf_cv_lib_XCurses,[
3297 CF_ADD_LIBS(-lXCurses)
3298 AC_TRY_LINK([
3299 #include <xcurses.h>
3300 char *XCursesProgramName = "test";
3301 ],[XCursesExit();],
3302 [cf_cv_lib_XCurses=yes],
3303 [cf_cv_lib_XCurses=no])
3304 ])
3305
3306 fi
3307
3308 if test "$cf_cv_lib_XCurses" = yes ; then
3309         AC_DEFINE(UNIX,1,[Define to 1 if using PDCurses on Unix])
3310         AC_DEFINE(XCURSES,1,[Define to 1 if using PDCurses on Unix])
3311         AC_CHECK_HEADER(xcurses.h, AC_DEFINE(HAVE_XCURSES,1,[Define to 1 if using PDCurses on Unix]))
3312 else
3313         AC_MSG_ERROR(Cannot link with XCurses)
3314 fi
3315 ])dnl
3316 dnl ---------------------------------------------------------------------------
3317 dnl CF_PKG_CONFIG version: 13 updated: 2023/10/28 11:59:01
3318 dnl -------------
3319 dnl Check for the package-config program, unless disabled by command-line.
3320 dnl
3321 dnl Sets $PKG_CONFIG to the pathname of the pkg-config program.
3322 AC_DEFUN([CF_PKG_CONFIG],
3323 [
3324 AC_MSG_CHECKING(if you want to use pkg-config)
3325 AC_ARG_WITH(pkg-config,
3326         [[  --with-pkg-config[=CMD] enable/disable use of pkg-config and its name CMD]],
3327         [cf_pkg_config=$withval],
3328         [cf_pkg_config=yes])
3329 AC_MSG_RESULT($cf_pkg_config)
3330
3331 case "$cf_pkg_config" in
3332 (no)
3333         PKG_CONFIG=none
3334         ;;
3335 (yes)
3336         CF_ACVERSION_CHECK(2.52,
3337                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
3338                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
3339         ;;
3340 (*)
3341         PKG_CONFIG=$withval
3342         ;;
3343 esac
3344
3345 test -z "$PKG_CONFIG" && PKG_CONFIG=none
3346 if test "$PKG_CONFIG" != none ; then
3347         CF_PATH_SYNTAX(PKG_CONFIG)
3348 elif test "x$cf_pkg_config" != xno ; then
3349         AC_MSG_WARN(pkg-config is not installed)
3350 fi
3351
3352 AC_SUBST(PKG_CONFIG)
3353 ])dnl
3354 dnl ---------------------------------------------------------------------------
3355 dnl CF_POSIX_C_SOURCE version: 12 updated: 2023/02/18 17:41:25
3356 dnl -----------------
3357 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
3358 dnl
3359 dnl     POSIX.1-1990                            _POSIX_SOURCE
3360 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
3361 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
3362 dnl             Bindings Option
3363 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
3364 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
3365 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
3366 dnl
3367 dnl Parameters:
3368 dnl     $1 is the nominal value for _POSIX_C_SOURCE
3369 AC_DEFUN([CF_POSIX_C_SOURCE],
3370 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
3371
3372 if test "$cf_cv_posix_visible" = no; then
3373
3374 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
3375
3376 cf_save_CFLAGS="$CFLAGS"
3377 cf_save_CPPFLAGS="$CPPFLAGS"
3378
3379 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
3380 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
3381
3382 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
3383         CF_MSG_LOG(if the symbol is already defined go no further)
3384         AC_TRY_COMPILE([#include <sys/types.h>],[
3385 #ifndef _POSIX_C_SOURCE
3386 #error _POSIX_C_SOURCE is not defined
3387 #endif],
3388         [cf_cv_posix_c_source=no],
3389         [cf_want_posix_source=no
3390          case .$cf_POSIX_C_SOURCE in
3391          (.[[12]]??*)
3392                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3393                 ;;
3394          (.2)
3395                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3396                 cf_want_posix_source=yes
3397                 ;;
3398          (.*)
3399                 cf_want_posix_source=yes
3400                 ;;
3401          esac
3402          if test "$cf_want_posix_source" = yes ; then
3403                 AC_TRY_COMPILE([#include <sys/types.h>],[
3404 #ifdef _POSIX_SOURCE
3405 #error _POSIX_SOURCE is defined
3406 #endif],[],
3407                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
3408          fi
3409          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
3410          CFLAGS="$cf_trim_CFLAGS"
3411          CPPFLAGS="$cf_trim_CPPFLAGS"
3412          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
3413          CF_MSG_LOG(if the second compile does not leave our definition intact error)
3414          AC_TRY_COMPILE([#include <sys/types.h>],[
3415 #ifndef _POSIX_C_SOURCE
3416 #error _POSIX_C_SOURCE is not defined
3417 #endif],,
3418          [cf_cv_posix_c_source=no])
3419          CFLAGS="$cf_save_CFLAGS"
3420          CPPFLAGS="$cf_save_CPPFLAGS"
3421         ])
3422 ])
3423
3424 if test "$cf_cv_posix_c_source" != no ; then
3425         CFLAGS="$cf_trim_CFLAGS"
3426         CPPFLAGS="$cf_trim_CPPFLAGS"
3427         CF_ADD_CFLAGS($cf_cv_posix_c_source)
3428 fi
3429
3430 fi # cf_cv_posix_visible
3431
3432 ])dnl
3433 dnl ---------------------------------------------------------------------------
3434 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
3435 dnl ----------------
3436 dnl POSIX documents test-macros which an application may set before any system
3437 dnl headers are included to make features available.
3438 dnl
3439 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
3440 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
3441 dnl recent features visible in the system header files unless the application
3442 dnl overrides the corresponding test-macros.  Doing that introduces portability
3443 dnl problems.
3444 dnl
3445 dnl This macro makes a special check for the symbols used for this, to avoid a
3446 dnl conflicting definition.
3447 AC_DEFUN([CF_POSIX_VISIBLE],
3448 [
3449 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
3450 AC_TRY_COMPILE([#include <stdio.h>],[
3451 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
3452         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
3453         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
3454         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
3455 #error conflicting symbols found
3456 #endif
3457 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
3458 ])
3459 ])dnl
3460 dnl ---------------------------------------------------------------------------
3461 dnl CF_PRG_RULES version: 2 updated: 2021/01/01 13:31:04
3462 dnl ------------
3463 dnl Append definitions and rules for the given programs to the subdirectory
3464 dnl Makefiles, and the recursion rule for the top-level Makefile.
3465 dnl
3466 dnl parameters
3467 dnl     $1 = script to run
3468 dnl     $2 = list of subdirectories
3469 dnl
3470 dnl variables
3471 dnl     $AWK
3472 AC_DEFUN([CF_PRG_RULES],
3473 [
3474 for cf_dir in $2
3475 do
3476         if test ! -d "$srcdir/$cf_dir" ; then
3477                 continue
3478         elif test -f "$srcdir/$cf_dir/programs" ; then
3479                 $AWK -f $1 "$srcdir/$cf_dir/programs" >>$cf_dir/Makefile
3480         fi
3481 done
3482
3483 ])dnl
3484 dnl ---------------------------------------------------------------------------
3485 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
3486 dnl ----------
3487 dnl standard check for CC, plus followup sanity checks
3488 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
3489 AC_DEFUN([CF_PROG_CC],[
3490 CF_ACVERSION_CHECK(2.53,
3491         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
3492          AC_REQUIRE([AC_PROG_CC])],
3493         [])
3494 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
3495 CF_GCC_VERSION
3496 CF_ACVERSION_CHECK(2.52,
3497         [AC_PROG_CC_STDC],
3498         [CF_ANSI_CC_REQD])
3499 CF_CC_ENV_FLAGS
3500 ])dnl
3501 dnl ---------------------------------------------------------------------------
3502 dnl CF_PROG_INSTALL version: 10 updated: 2021/01/04 19:33:05
3503 dnl ---------------
3504 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
3505 dnl misc/tabset install won't work properly.  Usually this happens only when
3506 dnl using the fallback mkinstalldirs script
3507 AC_DEFUN([CF_PROG_INSTALL],
3508 [AC_PROG_INSTALL
3509 case $INSTALL in
3510 (/*)
3511         ;;
3512 (*)
3513         CF_DIRNAME(cf_dir,$INSTALL)
3514         test -z "$cf_dir" && cf_dir=.
3515         INSTALL="`cd \"$cf_dir\" && pwd`"/"`echo "$INSTALL" | sed -e 's%^.*/%%'`"
3516         ;;
3517 esac
3518 ])dnl
3519 dnl ---------------------------------------------------------------------------
3520 dnl CF_PROG_LINT version: 5 updated: 2022/08/20 15:44:13
3521 dnl ------------
3522 AC_DEFUN([CF_PROG_LINT],
3523 [
3524 AC_CHECK_PROGS(LINT, lint cppcheck splint)
3525 case "x$LINT" in
3526 (xcppcheck|x*/cppcheck)
3527         test -z "$LINT_OPTS" && LINT_OPTS="--enable=all"
3528         ;;
3529 esac
3530 AC_SUBST(LINT_OPTS)
3531 AC_SUBST(LINT_LIBS)
3532 ])dnl
3533 dnl ---------------------------------------------------------------------------
3534 dnl CF_REMOVE_CFLAGS version: 3 updated: 2021/09/05 17:25:40
3535 dnl ----------------
3536 dnl Remove a given option from CFLAGS/CPPFLAGS
3537 dnl $1 = option to remove
3538 dnl $2 = variable to update
3539 dnl $3 = nonempty to allow verbose message
3540 define([CF_REMOVE_CFLAGS],
3541 [
3542 cf_tmp_cflag=`echo "x$1" | sed -e 's/^.//' -e 's/=.*//'`
3543 while true
3544 do
3545         cf_old_cflag=`echo "x[$]$2" | sed -e 's/^.//' -e 's/[[  ]][[    ]]*-/ -/g' -e "s%$cf_tmp_cflag\\(=[[^   ]][[^   ]]*\\)\?%%" -e 's/^[[   ]]*//' -e 's%[[ ]][[ ]]*-D% -D%g' -e 's%[[ ]][[ ]]*-I% -I%g'`
3546         test "[$]$2" != "$cf_old_cflag" || break
3547         ifelse([$3],,,[CF_VERBOSE(removing old option $1 from $2)])
3548         $2="$cf_old_cflag"
3549 done
3550 ])dnl
3551 dnl ---------------------------------------------------------------------------
3552 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
3553 dnl ----------------
3554 dnl Remove all -U and -D options that refer to the given symbol from a list
3555 dnl of C compiler options.  This works around the problem that not all
3556 dnl compilers process -U and -D options from left-to-right, so a -U option
3557 dnl cannot be used to cancel the effect of a preceding -D option.
3558 dnl
3559 dnl $1 = target (which could be the same as the source variable)
3560 dnl $2 = source (including '$')
3561 dnl $3 = symbol to remove
3562 define([CF_REMOVE_DEFINE],
3563 [
3564 $1=`echo "$2" | \
3565         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
3566                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
3567 ])dnl
3568 dnl ---------------------------------------------------------------------------
3569 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
3570 dnl ---------------------
3571 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
3572 dnl $1 = name of current macro
3573 define([CF_RESTORE_XTRA_FLAGS],
3574 [
3575 LIBS="$cf_save_LIBS_$1"
3576 CFLAGS="$cf_save_CFLAGS_$1"
3577 CPPFLAGS="$cf_save_CPPFLAGS_$1"
3578 ])dnl
3579 dnl ---------------------------------------------------------------------------
3580 dnl CF_RPATH_HACK version: 13 updated: 2021/01/03 18:30:50
3581 dnl -------------
3582 AC_DEFUN([CF_RPATH_HACK],
3583 [AC_REQUIRE([AC_PROG_FGREP])dnl
3584 AC_REQUIRE([CF_LD_RPATH_OPT])dnl
3585
3586 AC_MSG_CHECKING(for updated LDFLAGS)
3587 if test -n "$LD_RPATH_OPT" ; then
3588         AC_MSG_RESULT(maybe)
3589
3590         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
3591         cf_rpath_list="/usr/lib /lib"
3592         if test "$cf_ldd_prog" != no
3593         then
3594                 cf_rpath_oops=
3595
3596 AC_TRY_LINK([#include <stdio.h>],
3597                 [printf("Hello");],
3598                 [cf_rpath_oops=`"$cf_ldd_prog" "conftest$ac_exeext" | ${FGREP-fgrep} ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
3599                  cf_rpath_list=`"$cf_ldd_prog" "conftest$ac_exeext" | ${FGREP-fgrep} / | sed -e 's%^.*[[        ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
3600
3601                 # If we passed the link-test, but get a "not found" on a given library,
3602                 # this could be due to inept reconfiguration of gcc to make it only
3603                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
3604                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
3605                 # /usr/local libraries.
3606                 if test -n "$cf_rpath_oops"
3607                 then
3608                         for cf_rpath_src in $cf_rpath_oops
3609                         do
3610                                 for cf_rpath_dir in \
3611                                         /usr/local \
3612                                         /usr/pkg \
3613                                         /opt/sfw
3614                                 do
3615                                         if test -f "$cf_rpath_dir/lib/$cf_rpath_src"
3616                                         then
3617                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
3618                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
3619                                                 break
3620                                         fi
3621                                 done
3622                         done
3623                 fi
3624         fi
3625
3626         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
3627
3628         CF_RPATH_HACK_2(LDFLAGS)
3629         CF_RPATH_HACK_2(LIBS)
3630
3631         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
3632 else
3633         AC_MSG_RESULT(no)
3634 fi
3635 AC_SUBST(EXTRA_LDFLAGS)
3636 ])dnl
3637 dnl ---------------------------------------------------------------------------
3638 dnl CF_RPATH_HACK_2 version: 8 updated: 2021/01/01 13:31:04
3639 dnl ---------------
3640 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
3641 dnl EXTRA_LDFLAGS for each -L option found.
3642 dnl
3643 dnl $cf_rpath_list contains a list of directories to ignore.
3644 dnl
3645 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
3646 dnl      but LIBS often has misplaced -L options.
3647 AC_DEFUN([CF_RPATH_HACK_2],
3648 [
3649 CF_VERBOSE(...checking $1 [$]$1)
3650
3651 cf_rpath_dst=
3652 for cf_rpath_src in [$]$1
3653 do
3654         case "$cf_rpath_src" in
3655         (-L*)
3656
3657                 # check if this refers to a directory which we will ignore
3658                 cf_rpath_skip=no
3659                 if test -n "$cf_rpath_list"
3660                 then
3661                         for cf_rpath_item in $cf_rpath_list
3662                         do
3663                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
3664                                 then
3665                                         cf_rpath_skip=yes
3666                                         break
3667                                 fi
3668                         done
3669                 fi
3670
3671                 if test "$cf_rpath_skip" = no
3672                 then
3673                         # transform the option
3674                         if test "$LD_RPATH_OPT" = "-R " ; then
3675                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
3676                         else
3677                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
3678                         fi
3679
3680                         # if we have not already added this, add it now
3681                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
3682                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
3683                         then
3684                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
3685                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
3686                         fi
3687                 fi
3688                 ;;
3689         esac
3690         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
3691 done
3692 $1=$cf_rpath_dst
3693
3694 CF_VERBOSE(...checked $1 [$]$1)
3695 AC_SUBST(EXTRA_LDFLAGS)
3696 ])dnl
3697 dnl ---------------------------------------------------------------------------
3698 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
3699 dnl ------------------
3700 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
3701 dnl and libraries which do not update those variables.
3702 dnl
3703 dnl $1 = name of current macro
3704 define([CF_SAVE_XTRA_FLAGS],
3705 [
3706 cf_save_LIBS_$1="$LIBS"
3707 cf_save_CFLAGS_$1="$CFLAGS"
3708 cf_save_CPPFLAGS_$1="$CPPFLAGS"
3709 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
3710 for cf_X_CFLAGS in $X_CFLAGS
3711 do
3712         case "x$cf_X_CFLAGS" in
3713         x-[[IUD]]*)
3714                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
3715                 ;;
3716         *)
3717                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
3718                 ;;
3719         esac
3720 done
3721 ])dnl
3722 dnl ---------------------------------------------------------------------------
3723 dnl CF_SIGWINCH version: 7 updated: 2023/02/18 17:41:25
3724 dnl -----------
3725 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
3726 dnl programs need this test).
3727 dnl
3728 dnl This is really a Mac OS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
3729 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
3730 dnl winsize declaration is left alone - we may revisit this if Apple choose to
3731 dnl break that part of the interface as well.
3732 AC_DEFUN([CF_SIGWINCH],
3733 [
3734 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
3735         AC_TRY_COMPILE([
3736 #include <sys/types.h>
3737 #include <sys/signal.h>
3738 ],[int x = SIGWINCH; (void)x],
3739         [cf_cv_define_sigwinch=yes],
3740         [AC_TRY_COMPILE([
3741 #undef _XOPEN_SOURCE
3742 #undef _POSIX_SOURCE
3743 #undef _POSIX_C_SOURCE
3744 #include <sys/types.h>
3745 #include <sys/signal.h>
3746 ],[int x = SIGWINCH; (void)x],
3747         [cf_cv_define_sigwinch=maybe],
3748         [cf_cv_define_sigwinch=no])
3749 ])
3750 ])
3751
3752 if test "$cf_cv_define_sigwinch" = maybe ; then
3753 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
3754 cf_cv_fixup_sigwinch=unknown
3755 cf_sigwinch=32
3756 while test "$cf_sigwinch" != 1
3757 do
3758         AC_TRY_COMPILE([
3759 #undef _XOPEN_SOURCE
3760 #undef _POSIX_SOURCE
3761 #undef _POSIX_C_SOURCE
3762 #include <sys/types.h>
3763 #include <sys/signal.h>
3764 ],[
3765 #if SIGWINCH != $cf_sigwinch
3766 #error SIGWINCH is not $cf_sigwinch
3767 #endif
3768 int x = SIGWINCH; (void)x],
3769         [cf_cv_fixup_sigwinch=$cf_sigwinch
3770          break])
3771
3772 cf_sigwinch="`expr "$cf_sigwinch" - 1`"
3773 done
3774 ])
3775
3776         if test "$cf_cv_fixup_sigwinch" != unknown ; then
3777                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
3778         fi
3779 fi
3780 ])dnl
3781 dnl ---------------------------------------------------------------------------
3782 dnl CF_SIG_ATOMIC_T version: 5 updated: 2020/03/10 18:53:47
3783 dnl ---------------
3784 dnl signal handler, but there are some gcc dependencies in that recommendation.
3785 dnl Try anyway.
3786 AC_DEFUN([CF_SIG_ATOMIC_T],
3787 [
3788 AC_MSG_CHECKING(for signal global datatype)
3789 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
3790         for cf_type in \
3791                 "volatile sig_atomic_t" \
3792                 "sig_atomic_t" \
3793                 "int"
3794         do
3795         AC_TRY_COMPILE([
3796 #include <sys/types.h>
3797 #include <signal.h>
3798 #include <stdio.h>
3799
3800 extern $cf_type x;
3801 $cf_type x;
3802 static void handler(int sig)
3803 {
3804         (void)sig;
3805         x = 5;
3806 }],
3807                 [signal(SIGINT, handler);
3808                  x = 1],
3809                 [cf_cv_sig_atomic_t=$cf_type],
3810                 [cf_cv_sig_atomic_t=no])
3811                 test "$cf_cv_sig_atomic_t" != no && break
3812         done
3813         ])
3814 AC_MSG_RESULT($cf_cv_sig_atomic_t)
3815 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
3816 ])dnl
3817 dnl ---------------------------------------------------------------------------
3818 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
3819 dnl --------------
3820 dnl Construct a search-list for a nonstandard header/lib-file
3821 dnl     $1 = the variable to return as result
3822 dnl     $2 = the package name
3823 dnl     $3 = the subdirectory, e.g., bin, include or lib
3824 AC_DEFUN([CF_SUBDIR_PATH],
3825 [
3826 $1=
3827
3828 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
3829
3830 for cf_subdir_prefix in \
3831         /usr \
3832         /usr/local \
3833         /usr/pkg \
3834         /opt \
3835         /opt/local \
3836         [$]HOME
3837 do
3838         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
3839 done
3840 ])dnl
3841 dnl ---------------------------------------------------------------------------
3842 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
3843 dnl ------------------
3844 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
3845 dnl older SCO configurations.
3846 AC_DEFUN([CF_SYS_TIME_SELECT],
3847 [
3848 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
3849 AC_CACHE_VAL(cf_cv_sys_time_select,[
3850 AC_TRY_COMPILE([
3851 #include <sys/types.h>
3852 #ifdef HAVE_SYS_TIME_H
3853 #include <sys/time.h>
3854 #endif
3855 #ifdef HAVE_SYS_SELECT_H
3856 #include <sys/select.h>
3857 #endif
3858 ],[],[cf_cv_sys_time_select=yes],
3859          [cf_cv_sys_time_select=no])
3860          ])
3861 AC_MSG_RESULT($cf_cv_sys_time_select)
3862 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
3863 ])dnl
3864 dnl ---------------------------------------------------------------------------
3865 dnl CF_TERM_HEADER version: 6 updated: 2021/01/02 09:31:20
3866 dnl --------------
3867 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
3868 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
3869 dnl but some packagers change this, breaking various applications.
3870 AC_DEFUN([CF_TERM_HEADER],[
3871 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
3872 case "${cf_cv_ncurses_header}" in
3873 (*/ncurses.h|*/ncursesw.h)
3874         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
3875         ;;
3876 (*)
3877         cf_term_header=term.h
3878         ;;
3879 esac
3880
3881 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
3882 do
3883 AC_TRY_COMPILE([#include <stdio.h>
3884 #include <${cf_cv_ncurses_header:-curses.h}>
3885 #include <$cf_test>
3886 ],[int x = auto_left_margin; (void)x],[
3887         cf_cv_term_header="$cf_test"],[
3888         cf_cv_term_header=unknown
3889         ])
3890         test "$cf_cv_term_header" != unknown && break
3891 done
3892 ])
3893
3894 # Set definitions to allow ifdef'ing to accommodate subdirectories
3895
3896 case "$cf_cv_term_header" in
3897 (*term.h)
3898         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
3899         ;;
3900 esac
3901
3902 case "$cf_cv_term_header" in
3903 (ncurses/term.h)
3904         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
3905         ;;
3906 (ncursesw/term.h)
3907         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
3908         ;;
3909 esac
3910 ])dnl
3911 dnl ---------------------------------------------------------------------------
3912 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
3913 dnl ---------------
3914 dnl Define a top_builddir symbol, for applications that need an absolute path.
3915 AC_DEFUN([CF_TOP_BUILDDIR],
3916 [
3917 top_builddir=ifelse($1,,`pwd`,$1)
3918 AC_SUBST(top_builddir)
3919 ])dnl
3920 dnl ---------------------------------------------------------------------------
3921 dnl CF_TPUTS_PROTO version: 4 updated: 2021/01/04 19:45:09
3922 dnl --------------
3923 dnl Check for type of function-pointer passed to tputs.  Some old
3924 dnl implementations used functions that had different prototypes, making it
3925 dnl hard to compile portable programs using tputs.
3926 AC_DEFUN([CF_TPUTS_PROTO],[
3927 CF_CURSES_FUNCS(tputs)
3928 if test "x$cf_cv_func_tputs" = xyes
3929 then
3930         cf_done=no
3931         for cf_arg in int char
3932         do
3933                 for cf_ret in int void
3934                 do
3935                         if test "$cf_ret" = void
3936                         then
3937                                 cf_return="/* nothing */"
3938                         else
3939                                 cf_return="return value"
3940                         fi
3941                         AC_TRY_COMPILE([
3942 #include <${cf_cv_ncurses_header:-curses.h}>
3943 #include <$cf_cv_term_header>
3944
3945 static $cf_ret outc($cf_arg value) { $cf_return; }
3946 ],[
3947         tputs("hello", 0, outc);
3948         ${cf_cv_main_return:-return}(0);
3949 ],[
3950                 CF_VERBOSE([prototype $cf_ret func($cf_arg value)])
3951                 cat >>confdefs.h <<EOF
3952 #define TPUTS_ARG               $cf_arg
3953 #define TPUTS_PROTO(func,value) $cf_ret func(TPUTS_ARG value)
3954 #define TPUTS_RETURN(value)     $cf_return
3955 EOF
3956                 cf_done=yes
3957                 break
3958 ])
3959                 done
3960                 test "$cf_done" = yes && break
3961         done
3962 fi
3963 ])dnl
3964 dnl ---------------------------------------------------------------------------
3965 dnl CF_TRIM_X_LIBS version: 3 updated: 2015/04/12 15:39:00
3966 dnl --------------
3967 dnl Trim extra base X libraries added as a workaround for inconsistent library
3968 dnl dependencies returned by "new" pkg-config files.
3969 AC_DEFUN([CF_TRIM_X_LIBS],[
3970         for cf_trim_lib in Xmu Xt X11
3971         do
3972                 case "$LIBS" in
3973                 (*-l$cf_trim_lib\ *-l$cf_trim_lib*)
3974                         LIBS=`echo "$LIBS " | sed -e 's/  / /g' -e 's%-l'"$cf_trim_lib"' %%' -e 's/ $//'`
3975                         CF_VERBOSE(..trimmed $LIBS)
3976                         ;;
3977                 esac
3978         done
3979 ])
3980 dnl ---------------------------------------------------------------------------
3981 dnl CF_TRY_PKG_CONFIG version: 6 updated: 2020/12/31 10:54:15
3982 dnl -----------------
3983 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
3984 dnl available in that form.
3985 dnl
3986 dnl $1 = package name, which may be a shell variable
3987 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
3988 dnl $3 = logic to use if pkg-config does not have the package
3989 AC_DEFUN([CF_TRY_PKG_CONFIG],[
3990 AC_REQUIRE([CF_PKG_CONFIG])
3991
3992 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists "$1"; then
3993         CF_VERBOSE(found package $1)
3994         cf_pkgconfig_incs="`$PKG_CONFIG --cflags "$1" 2>/dev/null`"
3995         cf_pkgconfig_libs="`$PKG_CONFIG --libs   "$1" 2>/dev/null`"
3996         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
3997         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
3998         CF_ADD_CFLAGS($cf_pkgconfig_incs)
3999         CF_ADD_LIBS($cf_pkgconfig_libs)
4000         ifelse([$2],,:,[$2])
4001 else
4002         cf_pkgconfig_incs=
4003         cf_pkgconfig_libs=
4004         ifelse([$3],,:,[$3])
4005 fi
4006 ])
4007 dnl ---------------------------------------------------------------------------
4008 dnl CF_TRY_XOPEN_SOURCE version: 4 updated: 2022/09/10 15:16:16
4009 dnl -------------------
4010 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
4011 dnl can define it successfully.
4012 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
4013 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
4014         AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,
4015         [cf_cv_xopen_source=no],
4016         [cf_save="$CPPFLAGS"
4017          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
4018          AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,
4019                 [cf_cv_xopen_source=no],
4020                 [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
4021                 CPPFLAGS="$cf_save"
4022         ])
4023 ])
4024
4025 if test "$cf_cv_xopen_source" != no ; then
4026         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
4027         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
4028         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
4029         CF_APPEND_CFLAGS($cf_temp_xopen_source)
4030 fi
4031 ])
4032 dnl ---------------------------------------------------------------------------
4033 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
4034 dnl --------
4035 dnl Make an uppercase version of a variable
4036 dnl $1=uppercase($2)
4037 AC_DEFUN([CF_UPPER],
4038 [
4039 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4040 ])dnl
4041 dnl ---------------------------------------------------------------------------
4042 dnl CF_UTF8_LIB version: 10 updated: 2023/01/11 04:05:23
4043 dnl -----------
4044 dnl Check for multibyte support, and if not found, utf8 compatibility library
4045 AC_DEFUN([CF_UTF8_LIB],
4046 [
4047 AC_HAVE_HEADERS(wchar.h)
4048 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
4049         cf_save_LIBS="$LIBS"
4050         AC_TRY_LINK([
4051 $ac_includes_default
4052 #ifdef HAVE_WCHAR_H
4053 #include <wchar.h>
4054 #endif
4055 ],[putwc(0,0);],
4056         [cf_cv_utf8_lib=yes],
4057         [CF_FIND_LINKAGE([
4058 #include <libutf8.h>],[putwc(0,0);],utf8,
4059                 [cf_cv_utf8_lib=add-on],
4060                 [cf_cv_utf8_lib=no])
4061 ])])
4062
4063 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
4064 # ncurses/ncursesw:
4065 if test "$cf_cv_utf8_lib" = "add-on" ; then
4066         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
4067         CF_ADD_INCDIR($cf_cv_header_path_utf8)
4068         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
4069         CF_ADD_LIBS($cf_cv_library_file_utf8)
4070 fi
4071 ])dnl
4072 dnl ---------------------------------------------------------------------------
4073 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
4074 dnl ----------
4075 dnl Use AC_VERBOSE w/o the warnings
4076 AC_DEFUN([CF_VERBOSE],
4077 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
4078 CF_MSG_LOG([$1])
4079 ])dnl
4080 dnl ---------------------------------------------------------------------------
4081 dnl CF_WCHAR_TYPE version: 5 updated: 2023/12/03 09:21:34
4082 dnl -------------
4083 dnl Check if type wide-character type $1 is declared, and if so, which header
4084 dnl file is needed.  The second parameter is used to set a shell variable when
4085 dnl the type is not found.  The first parameter sets a shell variable for the
4086 dnl opposite sense.
4087 AC_DEFUN([CF_WCHAR_TYPE],
4088 [
4089 # This is needed on Tru64 5.0 to declare $1
4090 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
4091 AC_TRY_COMPILE([
4092 #include <stdlib.h>
4093 #include <stdarg.h>
4094 #include <stdio.h>
4095 #ifdef HAVE_LIBUTF8_H
4096 #include <libutf8.h>
4097 #endif],
4098         [$1 state; (void)state],
4099         [cf_cv_$1=no],
4100         [AC_TRY_COMPILE([
4101 #include <stdlib.h>
4102 #include <stdarg.h>
4103 #include <stdio.h>
4104 #include <wchar.h>
4105 #ifdef HAVE_LIBUTF8_H
4106 #include <libutf8.h>
4107 #endif],
4108         [$1 value; (void) value],
4109         [cf_cv_$1=yes],
4110         [cf_cv_$1=unknown])])])
4111
4112 if test "$cf_cv_$1" = yes ; then
4113         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
4114         NEED_WCHAR_H=1
4115 fi
4116
4117 ifelse([$2],,,[
4118 # if we do not find $1 in either place, use substitution to provide a fallback.
4119 if test "$cf_cv_$1" = unknown ; then
4120         $2=1
4121 fi
4122 ])
4123 ifelse($3,,,[
4124 # if we find $1 in either place, use substitution to provide a fallback.
4125 if test "$cf_cv_$1" != unknown ; then
4126         $3=1
4127 fi
4128 ])
4129 ])dnl
4130 dnl ---------------------------------------------------------------------------
4131 dnl CF_WITH_CURSES_DIR version: 4 updated: 2021/01/02 19:22:58
4132 dnl ------------------
4133 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
4134 dnl libraries.
4135 AC_DEFUN([CF_WITH_CURSES_DIR],[
4136
4137 AC_MSG_CHECKING(for specific curses-directory)
4138 AC_ARG_WITH(curses-dir,
4139         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
4140         [cf_cv_curses_dir=$withval],
4141         [cf_cv_curses_dir=no])
4142 AC_MSG_RESULT($cf_cv_curses_dir)
4143
4144 if test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no"
4145 then
4146         CF_PATH_SYNTAX(withval)
4147         if test -d "$cf_cv_curses_dir"
4148         then
4149                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
4150                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
4151         fi
4152 fi
4153 ])dnl
4154 dnl ---------------------------------------------------------------------------
4155 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
4156 dnl ----------------
4157 dnl Configure-option for dbmalloc.  The optional parameter is used to override
4158 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
4159 AC_DEFUN([CF_WITH_DBMALLOC],[
4160 CF_NO_LEAKS_OPTION(dbmalloc,
4161         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
4162         [USE_DBMALLOC])
4163
4164 if test "$with_dbmalloc" = yes ; then
4165         AC_CHECK_HEADER(dbmalloc.h,
4166                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
4167 fi
4168 ])dnl
4169 dnl ---------------------------------------------------------------------------
4170 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
4171 dnl ---------------
4172 dnl Configure-option for dmalloc.  The optional parameter is used to override
4173 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
4174 AC_DEFUN([CF_WITH_DMALLOC],[
4175 CF_NO_LEAKS_OPTION(dmalloc,
4176         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
4177         [USE_DMALLOC])
4178
4179 if test "$with_dmalloc" = yes ; then
4180         AC_CHECK_HEADER(dmalloc.h,
4181                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
4182 fi
4183 ])dnl
4184 dnl ---------------------------------------------------------------------------
4185 dnl CF_WITH_LIB_BASENAME version: 2 updated: 2023/11/22 20:48:30
4186 dnl --------------------
4187 dnl Allow for overriding the basename of a library, i.e., the part to which
4188 dnl prefixes/suffixes are attached.
4189 dnl
4190 dnl $1 = variable to set
4191 dnl $2 = option name
4192 dnl $3 = default basename for library, if omitted use $2
4193 AC_DEFUN([CF_WITH_LIB_BASENAME],
4194 [
4195 AC_MSG_CHECKING(for desired basename for $2 library)
4196 AC_ARG_WITH($2-libname,
4197         [[  --with-$2-libname[=XXX] override ifelse($3,,$2,$3) basename of library]],
4198         [with_lib_basename=$withval],
4199         [with_lib_basename=ifelse($3,,$2,$3)])
4200 $1="$with_lib_basename"
4201
4202 case "x[$]$1" in
4203 (x|xno|xnone|xyes)
4204         $1=ifelse($3,,$2,$3)
4205         ;;
4206 (*)
4207         ;;
4208 esac
4209
4210 AC_MSG_RESULT([$]$1)
4211 AC_SUBST($1)
4212 ])dnl
4213 dnl ---------------------------------------------------------------------------
4214 dnl CF_WITH_NCURSES_ETC version: 6 updated: 2023/01/16 10:10:06
4215 dnl -------------------
4216 dnl Use this macro for programs which use any variant of "curses", e.g.,
4217 dnl "ncurses", and "PDCurses".  Programs that can use curses and some unrelated
4218 dnl library (such as slang) should use a "--with-screen=XXX" option.
4219 dnl
4220 dnl This does not use AC_DEFUN, because that would tell autoconf to run each
4221 dnl of the macros inside this one - before this macro.
4222 define([CF_WITH_NCURSES_ETC],[
4223 CF_WITH_CURSES_DIR
4224
4225 cf_cv_screen=curses
4226
4227 AC_MSG_CHECKING(for specified curses library type)
4228 AC_ARG_WITH(screen,
4229         [  --with-screen=XXX       use specified curses-libraries],
4230         [cf_cv_screen=$withval],[
4231
4232 AC_ARG_WITH(ncursesw,
4233         [  --with-ncursesw         use wide ncurses-libraries],
4234         [cf_cv_screen=ncursesw],[
4235
4236 AC_ARG_WITH(ncurses,
4237         [  --with-ncurses          use ncurses-libraries],
4238         [cf_cv_screen=ncurses],[
4239
4240 AC_ARG_WITH(pdcurses,
4241         [  --with-pdcurses         compile/link with pdcurses X11 library],
4242         [cf_cv_screen=pdcurses],[
4243
4244 AC_ARG_WITH(curses-colr,
4245         [  --with-curses-colr      compile/link with HPUX 10.x color-curses],
4246         [cf_cv_screen=curses_colr],[
4247
4248 AC_ARG_WITH(curses-5lib,
4249         [  --with-curses-5lib      compile/link with SunOS 5lib curses],
4250         [cf_cv_screen=curses_5lib])])])])])])
4251
4252 AC_MSG_RESULT($cf_cv_screen)
4253
4254 case $cf_cv_screen in
4255 (curses|curses_*)
4256         CF_CURSES_CONFIG
4257         ;;
4258 (ncursesw*)
4259         CF_UTF8_LIB
4260         CF_NCURSES_CONFIG($cf_cv_screen)
4261         ;;
4262 (ncurses*)
4263         CF_NCURSES_CONFIG($cf_cv_screen)
4264         ;;
4265 (pdcurses)
4266         CF_PDCURSES_X11
4267         ;;
4268 (*)
4269         AC_MSG_ERROR(unexpected screen-value: $cf_cv_screen)
4270         ;;
4271 esac
4272
4273 CF_NCURSES_PTHREADS($cf_cv_screen)
4274 AC_SUBST(cf_cv_screen)
4275
4276 ])dnl
4277 dnl ---------------------------------------------------------------------------
4278 dnl CF_WITH_SCREEN_PDCURSES version: 1 updated: 2020/08/28 16:56:27
4279 dnl -----------------------
4280 dnl Call this macro before CF_ENABLE_WARNINGS for configure scripts which use
4281 dnl the "--with-screen=pdcurses" selection.  Doing that allows the configure
4282 dnl script to search for the X11/Xt header files to declare (or not) the
4283 dnl symbol needed to enable "const" in those header files.  If that configure
4284 dnl option is not used, then those checks are unnecessary.
4285 AC_DEFUN([CF_WITH_SCREEN_PDCURSES],[
4286 AC_PROVIDE([AC_PATH_XTRA])
4287 AC_PROVIDE([AC_PATH_X])
4288 if test -n "$with_screen" && test "x$with_screen" = "xpdcurses"
4289 then
4290         AC_PATH_X
4291         AC_PATH_XTRA
4292 fi
4293 ])dnl
4294 dnl ---------------------------------------------------------------------------
4295 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
4296 dnl ----------------
4297 AC_DEFUN([CF_WITH_VALGRIND],[
4298 CF_NO_LEAKS_OPTION(valgrind,
4299         [  --with-valgrind         test: use valgrind],
4300         [USE_VALGRIND])
4301 ])dnl
4302 dnl ---------------------------------------------------------------------------
4303 dnl CF_WITH_X11_RGB version: 3 updated: 2023/10/28 11:59:01
4304 dnl ---------------
4305 dnl Handle configure option "--with-x11-rgb", setting these shell
4306 dnl variables:
4307 dnl
4308 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
4309 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
4310 dnl
4311 dnl Most Linux's use this:
4312 dnl     /usr/share/X11/rgb.txt
4313 dnl Debian uses this:
4314 dnl     /etc/X11/rgb.txt
4315 dnl DragonFlyBSD ports uses this:
4316 dnl     /usr/pkg/lib/X11/rgb.txt
4317 dnl FreeBSD ports use these:
4318 dnl     /usr/local/lib/X11/rgb.txt
4319 dnl     /usr/local/share/X11/rgb.txt
4320 dnl Mandriva has these:
4321 dnl     /usr/lib/X11/rgb.txt
4322 dnl     /usr/lib64/X11/rgb.txt
4323 dnl NetBSD has these
4324 dnl     /usr/X11R7/lib/X11/rgb.txt
4325 dnl OpenSolaris uses
4326 dnl     32-bit:
4327 dnl     /usr/X11/etc/X11/rgb.txt
4328 dnl     /usr/X11/share/X11/rgb.txt
4329 dnl     /usr/X11/lib/X11/rgb.txt
4330 dnl OSX uses
4331 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
4332 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
4333 dnl     64-bit:
4334 dnl     /usr/X11/etc/X11/rgb.txt
4335 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
4336 dnl     /usr/X11/lib/amd64/X11/rgb.txt
4337 dnl Solaris10 uses (in this order):
4338 dnl     /usr/openwin/lib/X11/rgb.txt
4339 dnl     /usr/X11/lib/X11/rgb.txt
4340 AC_DEFUN([CF_WITH_X11_RGB],[
4341 AC_MSG_CHECKING(for X11 rgb file)
4342 AC_ARG_WITH(x11-rgb,
4343         [  --with-x11-rgb=FILE     obtain X11 color definitions from FILE (default: EPREFIX/lib/X11/rgb.txt)],
4344         [RGB_PATH=$withval],
4345         [RGB_PATH=auto])
4346
4347 if test "x[$]RGB_PATH" = xauto
4348 then
4349         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
4350         for cf_path in \
4351                 /opt/local/share/X11/rgb.txt \
4352                 /opt/X11/share/X11/rgb.txt \
4353                 /usr/share/X11/rgb.txt \
4354                 /usr/X11/share/X11/rgb.txt \
4355                 /usr/X11/lib/X11/rgb.txt \
4356                 /usr/lib/X11/rgb.txt \
4357                 /etc/X11/rgb.txt \
4358                 /usr/pkg/lib/X11/rgb.txt \
4359                 /usr/X11R7/lib/X11/rgb.txt \
4360                 /usr/X11R6/lib/X11/rgb.txt \
4361                 /usr/X11R5/lib/X11/rgb.txt \
4362                 /usr/X11R4/lib/X11/rgb.txt \
4363                 /usr/local/lib/X11/rgb.txt \
4364                 /usr/local/share/X11/rgb.txt \
4365                 /usr/lib64/X11/rgb.txt
4366         do
4367                 if test -f "$cf_path" ; then
4368                         RGB_PATH="$cf_path"
4369                         break
4370                 fi
4371         done
4372 else
4373         cf_path=$RGB_PATH
4374         CF_PATH_SYNTAX(cf_path)
4375 fi
4376
4377 AC_MSG_RESULT($RGB_PATH)
4378 AC_SUBST(RGB_PATH)
4379 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path",[Define to the full pathname of rgb.txt])
4380
4381 no_x11_rgb=
4382 if test "$RGB_PATH" = no
4383 then
4384         no_x11_rgb="#"
4385 fi
4386 AC_SUBST(no_x11_rgb)
4387 ])dnl
4388 dnl ---------------------------------------------------------------------------
4389 dnl CF_XOPEN_CURSES version: 20 updated: 2024/01/07 06:54:12
4390 dnl ---------------
4391 dnl Test if we should define X/Open source for curses, needed on Digital Unix
4392 dnl 4.x, to see the extended functions, but breaks on IRIX 6.x.
4393 dnl
4394 dnl The getbegyx() check is needed for HPUX, which omits legacy macros such
4395 dnl as getbegy().  The latter is better design, but the former is standard.
4396 AC_DEFUN([CF_XOPEN_CURSES],
4397 [
4398 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
4399 AC_CACHE_CHECK(definition to turn on extended curses functions,cf_cv_need_xopen_extension,[
4400 cf_cv_need_xopen_extension=unknown
4401 AC_TRY_LINK([
4402 $ac_includes_default
4403 #include <${cf_cv_ncurses_header:-curses.h}>],[
4404 #if defined(NCURSES_VERSION_PATCH)
4405 #if (NCURSES_VERSION_PATCH < 20100501) && (NCURSES_VERSION_PATCH >= 20100403)
4406         #error disallow ncurses versions between 2020/04/03 and 2010/05/01
4407 #endif
4408 #endif
4409 #ifdef NCURSES_WIDECHAR
4410 #error prefer to fall-through on the second checks
4411 #endif
4412         static char dummy[10];
4413         cchar_t check;
4414         int check2 = curs_set((int)sizeof(check));
4415         long x = winnstr(stdscr, dummy, 5);
4416         int x1, y1;
4417         (void)check2;
4418         getbegyx(stdscr, y1, x1);
4419         (void)x;
4420         (void)y1;
4421         (void)x1;
4422         ],
4423         [cf_cv_need_xopen_extension=none],
4424         [
4425         for cf_try_xopen_extension in _XOPEN_SOURCE_EXTENDED NCURSES_WIDECHAR
4426         do
4427                 AC_TRY_LINK([
4428 #define $cf_try_xopen_extension 1
4429 $ac_includes_default
4430 #include <${cf_cv_ncurses_header:-curses.h}>],[
4431                 static char dummy[10];
4432                 cchar_t check;
4433                 int check2 = curs_set((int)sizeof(check));
4434                 long x = winnstr(stdscr, dummy, 5);
4435                 int x1, y1;
4436                 getbegyx(stdscr, y1, x1);
4437                 (void)check2;
4438                 (void)x;
4439                 (void)y1;
4440                 (void)x1;
4441                 ],
4442                 [cf_cv_need_xopen_extension=$cf_try_xopen_extension; break])
4443         done
4444         ])
4445 ])
4446
4447 case "$cf_cv_need_xopen_extension" in
4448 (*_*)
4449         CF_APPEND_TEXT(CPPFLAGS,-D$cf_cv_need_xopen_extension)
4450         ;;
4451 esac
4452
4453 ])dnl
4454 dnl ---------------------------------------------------------------------------
4455 dnl CF_XOPEN_SOURCE version: 67 updated: 2023/09/06 18:55:27
4456 dnl ---------------
4457 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
4458 dnl or adapt to the vendor's definitions to get equivalent functionality,
4459 dnl without losing the common non-POSIX features.
4460 dnl
4461 dnl Parameters:
4462 dnl     $1 is the nominal value for _XOPEN_SOURCE
4463 dnl     $2 is the nominal value for _POSIX_C_SOURCE
4464 dnl
4465 dnl The default case prefers _XOPEN_SOURCE over _POSIX_C_SOURCE if the
4466 dnl implementation predefines it, because X/Open and most implementations agree
4467 dnl that the latter is a legacy or "aligned" value.
4468 dnl
4469 dnl Because _XOPEN_SOURCE is preferred, if defining _POSIX_C_SOURCE turns
4470 dnl that off, then refrain from setting _POSIX_C_SOURCE explicitly.
4471 dnl
4472 dnl References:
4473 dnl https://pubs.opengroup.org/onlinepubs/007904975/functions/xsh_chap02_02.html
4474 dnl https://docs.oracle.com/cd/E19253-01/816-5175/standards-5/index.html
4475 dnl https://www.gnu.org/software/libc/manual/html_node/Feature-Test-Macros.html
4476 AC_DEFUN([CF_XOPEN_SOURCE],[
4477 AC_REQUIRE([AC_CANONICAL_HOST])
4478 AC_REQUIRE([CF_POSIX_VISIBLE])
4479
4480 if test "$cf_cv_posix_visible" = no; then
4481
4482 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
4483 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
4484 cf_xopen_source=
4485
4486 case "$host_os" in
4487 (aix[[4-7]]*)
4488         cf_xopen_source="-D_ALL_SOURCE"
4489         ;;
4490 (darwin[[0-8]].*)
4491         cf_xopen_source="-D_APPLE_C_SOURCE"
4492         ;;
4493 (darwin*)
4494         cf_xopen_source="-D_DARWIN_C_SOURCE"
4495         cf_XOPEN_SOURCE=
4496         ;;
4497 (freebsd*|dragonfly*|midnightbsd*)
4498         # 5.x headers associate
4499         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
4500         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
4501         cf_POSIX_C_SOURCE=200112L
4502         cf_XOPEN_SOURCE=600
4503         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
4504         ;;
4505 (hpux11*)
4506         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
4507         ;;
4508 (hpux*)
4509         cf_xopen_source="-D_HPUX_SOURCE"
4510         ;;
4511 (irix[[56]].*)
4512         cf_xopen_source="-D_SGI_SOURCE"
4513         cf_XOPEN_SOURCE=
4514         ;;
4515 (linux*gnu|linux*gnuabi64|linux*gnuabin32|linux*gnueabi|linux*gnueabihf|linux*gnux32|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin|msys|mingw*|linux*uclibc)
4516         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
4517         ;;
4518 (minix*)
4519         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
4520         ;;
4521 (mirbsd*)
4522         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
4523         cf_XOPEN_SOURCE=
4524         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
4525         ;;
4526 (netbsd*)
4527         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
4528         ;;
4529 (openbsd[[6-9]]*)
4530         # OpenBSD 6.x has broken locale support, both compile-time and runtime.
4531         # see https://www.mail-archive.com/bugs@openbsd.org/msg13200.html
4532         # Abusing the conformance level is a workaround.
4533         AC_MSG_WARN(this system does not provide usable locale support)
4534         cf_xopen_source="-D_BSD_SOURCE"
4535         cf_XOPEN_SOURCE=700
4536         ;;
4537 (openbsd[[4-5]]*)
4538         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
4539         cf_xopen_source="-D_BSD_SOURCE"
4540         cf_XOPEN_SOURCE=600
4541         ;;
4542 (openbsd*)
4543         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
4544         ;;
4545 (osf[[45]]*)
4546         cf_xopen_source="-D_OSF_SOURCE"
4547         ;;
4548 (nto-qnx*)
4549         cf_xopen_source="-D_QNX_SOURCE"
4550         ;;
4551 (sco*)
4552         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
4553         ;;
4554 (solaris2.*)
4555         cf_xopen_source="-D__EXTENSIONS__"
4556         cf_cv_xopen_source=broken
4557         ;;
4558 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
4559         cf_XOPEN_SOURCE=
4560         cf_POSIX_C_SOURCE=
4561         ;;
4562 (*)
4563         CF_TRY_XOPEN_SOURCE
4564         cf_save_xopen_cppflags="$CPPFLAGS"
4565         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
4566         # Some of these niche implementations use copy/paste, double-check...
4567         if test "$cf_cv_xopen_source" = no ; then
4568                 CF_VERBOSE(checking if _POSIX_C_SOURCE interferes with _XOPEN_SOURCE)
4569                 AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,,[
4570                         AC_MSG_WARN(_POSIX_C_SOURCE definition is not usable)
4571                         CPPFLAGS="$cf_save_xopen_cppflags"])
4572         fi
4573         ;;
4574 esac
4575
4576 if test -n "$cf_xopen_source" ; then
4577         CF_APPEND_CFLAGS($cf_xopen_source,true)
4578 fi
4579
4580 dnl In anything but the default case, we may have system-specific setting
4581 dnl which is still not guaranteed to provide all of the entrypoints that
4582 dnl _XOPEN_SOURCE would yield.
4583 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
4584         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
4585         AC_TRY_COMPILE([#include <stdlib.h>],[
4586 #ifndef _XOPEN_SOURCE
4587 #error _XOPEN_SOURCE is not defined
4588 #endif],
4589         [cf_XOPEN_SOURCE_set=yes],
4590         [cf_XOPEN_SOURCE_set=no])
4591         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
4592         if test "$cf_XOPEN_SOURCE_set" = yes
4593         then
4594                 AC_TRY_COMPILE([#include <stdlib.h>],[
4595 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
4596 #error (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
4597 #endif],
4598                 [cf_XOPEN_SOURCE_set_ok=yes],
4599                 [cf_XOPEN_SOURCE_set_ok=no])
4600                 if test "$cf_XOPEN_SOURCE_set_ok" = no
4601                 then
4602                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
4603                 fi
4604         else
4605                 CF_TRY_XOPEN_SOURCE
4606         fi
4607 fi
4608 fi # cf_cv_posix_visible
4609 ])
4610 dnl ---------------------------------------------------------------------------
4611 dnl CF_X_ATHENA version: 25 updated: 2023/01/11 04:05:23
4612 dnl -----------
4613 dnl Check for Xaw (Athena) libraries
4614 dnl
4615 dnl Sets $cf_x_athena according to the flavor of Xaw which is used.
4616 AC_DEFUN([CF_X_ATHENA],
4617 [
4618 cf_x_athena=${cf_x_athena:-Xaw}
4619
4620 AC_MSG_CHECKING(if you want to link with Xaw 3d library)
4621 withval=
4622 AC_ARG_WITH(Xaw3d,
4623         [  --with-Xaw3d            link with Xaw 3d library])
4624 if test "$withval" = yes ; then
4625         cf_x_athena=Xaw3d
4626         AC_MSG_RESULT(yes)
4627 else
4628         AC_MSG_RESULT(no)
4629 fi
4630
4631 AC_MSG_CHECKING(if you want to link with Xaw 3d xft library)
4632 withval=
4633 AC_ARG_WITH(Xaw3dxft,
4634         [  --with-Xaw3dxft         link with Xaw 3d xft library])
4635 if test "$withval" = yes ; then
4636         cf_x_athena=Xaw3dxft
4637         AC_MSG_RESULT(yes)
4638 else
4639         AC_MSG_RESULT(no)
4640 fi
4641
4642 AC_MSG_CHECKING(if you want to link with neXT Athena library)
4643 withval=
4644 AC_ARG_WITH(neXtaw,
4645         [  --with-neXtaw           link with neXT Athena library])
4646 if test "$withval" = yes ; then
4647         cf_x_athena=neXtaw
4648         AC_MSG_RESULT(yes)
4649 else
4650         AC_MSG_RESULT(no)
4651 fi
4652
4653 AC_MSG_CHECKING(if you want to link with Athena-Plus library)
4654 withval=
4655 AC_ARG_WITH(XawPlus,
4656         [  --with-XawPlus          link with Athena-Plus library])
4657 if test "$withval" = yes ; then
4658         cf_x_athena=XawPlus
4659         AC_MSG_RESULT(yes)
4660 else
4661         AC_MSG_RESULT(no)
4662 fi
4663
4664 cf_x_athena_lib=""
4665
4666 if test "$PKG_CONFIG" != none ; then
4667         cf_athena_list=
4668         test "$cf_x_athena" = Xaw && cf_athena_list="xaw8 xaw7 xaw6"
4669         for cf_athena_pkg in \
4670                 $cf_athena_list \
4671                 ${cf_x_athena} \
4672                 ${cf_x_athena}-devel \
4673                 lib${cf_x_athena} \
4674                 lib${cf_x_athena}-devel
4675         do
4676                 CF_TRY_PKG_CONFIG($cf_athena_pkg,[
4677                         cf_x_athena_lib="$cf_pkgconfig_libs"
4678                         CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
4679                         AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
4680
4681                         CF_TRIM_X_LIBS
4682
4683 AC_CACHE_CHECK(for usable $cf_x_athena/Xmu package,cf_cv_xaw_compat,[
4684 AC_TRY_LINK([
4685 $ac_includes_default
4686 #include <X11/Xmu/CharSet.h>
4687 ],[
4688 int check = XmuCompareISOLatin1("big", "small");
4689 (void)check;
4690 ],[cf_cv_xaw_compat=yes],[cf_cv_xaw_compat=no])])
4691
4692                         if test "$cf_cv_xaw_compat" = no
4693                         then
4694                                 # workaround for broken ".pc" files...
4695                                 case "$cf_x_athena_lib" in
4696                                 (*-lXmu*)
4697                                         ;;
4698                                 (*)
4699                                         CF_VERBOSE(work around broken package)
4700                                         cf_save_xmu="$LIBS"
4701                                         cf_first_lib=`echo "$cf_save_xmu" | sed -e 's/^[ ][ ]*//' -e 's/ .*//'`
4702                                         CF_TRY_PKG_CONFIG(xmu,[
4703                                                         LIBS="$cf_save_xmu"
4704                                                         CF_ADD_LIB_AFTER($cf_first_lib,$cf_pkgconfig_libs)
4705                                                 ],[
4706                                                         CF_ADD_LIB_AFTER($cf_first_lib,-lXmu)
4707                                                 ])
4708                                         CF_TRIM_X_LIBS
4709                                         ;;
4710                                 esac
4711                         fi
4712
4713                         break])
4714         done
4715 fi
4716
4717 if test -z "$cf_x_athena_lib" ; then
4718         CF_X_EXT
4719         CF_X_TOOLKIT
4720         CF_X_ATHENA_CPPFLAGS($cf_x_athena)
4721         CF_X_ATHENA_LIBS($cf_x_athena)
4722 fi
4723 ])dnl
4724 dnl ---------------------------------------------------------------------------
4725 dnl CF_X_ATHENA_CPPFLAGS version: 9 updated: 2020/12/31 10:54:15
4726 dnl --------------------
4727 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
4728 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
4729 AC_DEFUN([CF_X_ATHENA_CPPFLAGS],
4730 [
4731 AC_REQUIRE([AC_PATH_XTRA])
4732 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
4733 cf_x_athena_inc=""
4734
4735 for cf_path in default \
4736         /usr/contrib/X11R6 \
4737         /usr/contrib/X11R5 \
4738         /usr/lib/X11R5 \
4739         /usr/local
4740 do
4741         if test -z "$cf_x_athena_inc" ; then
4742                 CF_SAVE_XTRA_FLAGS([CF_X_ATHENA_CPPFLAGS])
4743                 cf_test=X11/$cf_x_athena_root/SimpleMenu.h
4744                 if test "$cf_path" != default ; then
4745                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_path/include)
4746                         AC_MSG_CHECKING(for $cf_test in $cf_path)
4747                 else
4748                         AC_MSG_CHECKING(for $cf_test)
4749                 fi
4750                 AC_TRY_COMPILE([
4751 #include <X11/Intrinsic.h>
4752 #include <$cf_test>],[],
4753                         [cf_result=yes],
4754                         [cf_result=no])
4755                 AC_MSG_RESULT($cf_result)
4756                 CF_RESTORE_XTRA_FLAGS([CF_X_ATHENA_CPPFLAGS])
4757                 if test "$cf_result" = yes ; then
4758                         test "$cf_path"  = default && cf_x_athena_inc=default
4759                         test "$cf_path" != default && cf_x_athena_inc="$cf_path/include"
4760                         break
4761                 fi
4762         fi
4763 done
4764
4765 if test -z "$cf_x_athena_inc" ; then
4766         AC_MSG_WARN([Unable to find Athena header files])
4767 elif test "$cf_x_athena_inc" != default ; then
4768         CF_APPEND_TEXT(CPPFLAGS,-I$cf_x_athena_inc)
4769 fi
4770 ])
4771 dnl ---------------------------------------------------------------------------
4772 dnl CF_X_ATHENA_LIBS version: 14 updated: 2023/01/11 04:05:23
4773 dnl ----------------
4774 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
4775 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
4776 AC_DEFUN([CF_X_ATHENA_LIBS],
4777 [AC_REQUIRE([CF_X_TOOLKIT])
4778 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
4779 cf_x_athena_lib=""
4780
4781 for cf_path in default \
4782         /usr/contrib/X11R6 \
4783         /usr/contrib/X11R5 \
4784         /usr/lib/X11R5 \
4785         /usr/local
4786 do
4787         for cf_lib in \
4788                 ${cf_x_athena_root} \
4789                 ${cf_x_athena_root}7 \
4790                 ${cf_x_athena_root}6
4791         do
4792         for cf_libs in \
4793                 "-l$cf_lib -lXmu" \
4794                 "-l$cf_lib -lXpm -lXmu" \
4795                 "-l${cf_lib}_s -lXmu_s"
4796         do
4797                 test -n "$cf_x_athena_lib" && break
4798
4799                 CF_SAVE_XTRA_FLAGS([CF_X_ATHENA_LIBS])
4800                 cf_test=XawSimpleMenuAddGlobalActions
4801                 test "$cf_path" != default && cf_libs="-L$cf_path/lib $cf_libs"
4802                 CF_ADD_LIBS($cf_libs)
4803                 AC_MSG_CHECKING(for $cf_test in $cf_libs)
4804                 AC_TRY_LINK([
4805 $ac_includes_default
4806 #include <X11/Intrinsic.h>
4807 #include <X11/$cf_x_athena_root/SimpleMenu.h>
4808 ],[
4809 $cf_test((XtAppContext) 0)],
4810                         [cf_result=yes],
4811                         [cf_result=no])
4812                 AC_MSG_RESULT($cf_result)
4813                 CF_RESTORE_XTRA_FLAGS([CF_X_ATHENA_LIBS])
4814
4815                 if test "$cf_result" = yes ; then
4816                         cf_x_athena_lib="$cf_libs"
4817                         break
4818                 fi
4819         done # cf_libs
4820                 test -n "$cf_x_athena_lib" && break
4821         done # cf_lib
4822 done
4823
4824 if test -z "$cf_x_athena_lib" ; then
4825         AC_MSG_ERROR(
4826 [Unable to successfully link Athena library (-l$cf_x_athena_root) with test program])
4827 fi
4828
4829 CF_ADD_LIBS($cf_x_athena_lib)
4830 CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
4831 AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
4832 ])
4833 dnl ---------------------------------------------------------------------------
4834 dnl CF_X_EXT version: 3 updated: 2010/06/02 05:03:05
4835 dnl --------
4836 AC_DEFUN([CF_X_EXT],[
4837 CF_TRY_PKG_CONFIG(Xext,,[
4838         AC_CHECK_LIB(Xext,XextCreateExtension,
4839                 [CF_ADD_LIB(Xext)])])
4840 ])dnl
4841 dnl ---------------------------------------------------------------------------
4842 dnl CF_X_TOOLKIT version: 27 updated: 2023/01/11 04:05:23
4843 dnl ------------
4844 dnl Check for X Toolkit libraries
4845 AC_DEFUN([CF_X_TOOLKIT],
4846 [
4847 AC_REQUIRE([AC_PATH_XTRA])
4848 AC_REQUIRE([CF_CHECK_CACHE])
4849
4850 # OSX is schizoid about who owns /usr/X11 (old) versus /opt/X11 (new) (and
4851 # in some cases has installed dummy files in the former, other cases replaced
4852 # it with a link to the new location).  This complicates the configure script.
4853 # Check for that pitfall, and recover using pkg-config
4854 #
4855 # If none of these are set, the configuration is almost certainly broken.
4856 if test -z "${X_CFLAGS}${X_PRE_LIBS}${X_LIBS}${X_EXTRA_LIBS}"
4857 then
4858         CF_TRY_PKG_CONFIG(x11,,[AC_MSG_WARN(unable to find X11 library)])
4859         CF_TRY_PKG_CONFIG(ice,,[AC_MSG_WARN(unable to find ICE library)])
4860         CF_TRY_PKG_CONFIG(sm,,[AC_MSG_WARN(unable to find SM library)])
4861         CF_TRY_PKG_CONFIG(xt,,[AC_MSG_WARN(unable to find Xt library)])
4862 else
4863         LIBS="$X_PRE_LIBS $LIBS $X_EXTRA_LIBS"
4864 fi
4865
4866 cf_have_X_LIBS=no
4867
4868 CF_TRY_PKG_CONFIG(xt,[
4869
4870         case "x$LIBS" in
4871         (*-lX11*)
4872                 ;;
4873         (*)
4874 # we have an "xt" package, but it may omit Xt's dependency on X11
4875 AC_CACHE_CHECK(for usable X dependency,cf_cv_xt_x11_compat,[
4876 AC_TRY_LINK([
4877 $ac_includes_default
4878 #include <X11/Xlib.h>
4879 ],[
4880         int rc1 = XDrawLine((Display*) 0, (Drawable) 0, (GC) 0, 0, 0, 0, 0);
4881         int rc2 = XClearWindow((Display*) 0, (Window) 0);
4882         int rc3 = XMoveWindow((Display*) 0, (Window) 0, 0, 0);
4883         int rc4 = XMoveResizeWindow((Display*)0, (Window)0, 0, 0, 0, 0);
4884 ],[cf_cv_xt_x11_compat=yes],[cf_cv_xt_x11_compat=no])])
4885                 if test "$cf_cv_xt_x11_compat" = no
4886                 then
4887                         CF_VERBOSE(work around broken X11 dependency)
4888                         # 2010/11/19 - good enough until a working Xt on Xcb is delivered.
4889                         CF_TRY_PKG_CONFIG(x11,,[CF_ADD_LIB_AFTER(-lXt,-lX11)])
4890                 fi
4891                 ;;
4892         esac
4893
4894 AC_CACHE_CHECK(for usable X Toolkit package,cf_cv_xt_ice_compat,[
4895 AC_TRY_LINK([
4896 $ac_includes_default
4897 #include <X11/Shell.h>
4898 ],[int num = IceConnectionNumber(0); (void) num
4899 ],[cf_cv_xt_ice_compat=yes],[cf_cv_xt_ice_compat=no])])
4900
4901         if test "$cf_cv_xt_ice_compat" = no
4902         then
4903                 # workaround for broken ".pc" files used for X Toolkit.
4904                 case "x$X_PRE_LIBS" in
4905                 (*-lICE*)
4906                         case "x$LIBS" in
4907                         (*-lICE*)
4908                                 ;;
4909                         (*)
4910                                 CF_VERBOSE(work around broken ICE dependency)
4911                                 CF_TRY_PKG_CONFIG(ice,
4912                                         [CF_TRY_PKG_CONFIG(sm)],
4913                                         [CF_ADD_LIB_AFTER(-lXt,$X_PRE_LIBS)])
4914                                 ;;
4915                         esac
4916                         ;;
4917                 esac
4918         fi
4919
4920         cf_have_X_LIBS=yes
4921 ],[
4922
4923         LDFLAGS="$X_LIBS $LDFLAGS"
4924         CF_CHECK_CFLAGS($X_CFLAGS)
4925
4926         AC_CHECK_FUNC(XOpenDisplay,,[
4927         AC_CHECK_LIB(X11,XOpenDisplay,
4928                 [CF_ADD_LIB(X11)])])
4929
4930         AC_CHECK_FUNC(XtAppInitialize,,[
4931         AC_CHECK_LIB(Xt, XtAppInitialize,
4932                 [AC_DEFINE(HAVE_LIBXT,1,[Define to 1 if we can compile with the Xt library])
4933                  cf_have_X_LIBS=Xt
4934                  LIBS="-lXt $LIBS"])])
4935 ])
4936
4937 if test "$cf_have_X_LIBS" = no ; then
4938         AC_MSG_WARN(
4939 [Unable to successfully link X Toolkit library (-lXt) with
4940 test program.  You will have to check and add the proper libraries by hand
4941 to makefile.])
4942 fi
4943 ])dnl
4944 dnl ---------------------------------------------------------------------------
4945 dnl CF__CURSES_DATA version: 3 updated: 2021/01/04 19:45:09
4946 dnl ---------------
4947 dnl Attempt to make a copy of a curses data item.  This is needed in the
4948 dnl check-data configure tests when using ncurses, because the symbol may be
4949 dnl actually a function return-value.  That could happen if the linker is
4950 dnl broken (does not resolve data-only references), or if ncurses is configured
4951 dnl to support re-entrant code.
4952 dnl $1 = target
4953 dnl $2 = source
4954 define([CF__CURSES_DATA],[
4955 #if defined($2) && ((defined(NCURSES_WRAPPED_VAR) && (NCURSES_VERSION_PATCH < 20200208)) || defined(NCURSES_BROKEN_LINKER) || defined(NCURSES_REENTRANT))
4956         const void *$1 = (const void *)($2);
4957 #else
4958         const void *$1 = &($2);
4959 #endif
4960         fprintf(stderr, "testing linkage of $2:%p\\n", (const void *)$1);
4961 ])dnl
4962 dnl ---------------------------------------------------------------------------
4963 dnl CF__CURSES_HEAD version: 2 updated: 2010/10/23 15:54:49
4964 dnl ---------------
4965 dnl Define a reusable chunk which includes <curses.h> and <term.h> when they
4966 dnl are both available.
4967 define([CF__CURSES_HEAD],[
4968 #ifdef HAVE_XCURSES
4969 #include <xcurses.h>
4970 char * XCursesProgramName = "test";
4971 #else
4972 #include <${cf_cv_ncurses_header:-curses.h}>
4973 #if defined(NCURSES_VERSION) && defined(HAVE_NCURSESW_TERM_H)
4974 #include <ncursesw/term.h>
4975 #elif defined(NCURSES_VERSION) && defined(HAVE_NCURSES_TERM_H)
4976 #include <ncurses/term.h>
4977 #elif defined(HAVE_TERM_H)
4978 #include <term.h>
4979 #endif
4980 #endif
4981 ])
4982 dnl ---------------------------------------------------------------------------
4983 dnl CF__XOPEN_SOURCE_BODY version: 2 updated: 2023/02/18 17:41:25
4984 dnl ---------------------
4985 dnl body of test when test-compiling for _XOPEN_SOURCE check
4986 define([CF__XOPEN_SOURCE_BODY],
4987 [
4988 #ifndef _XOPEN_SOURCE
4989 #error _XOPEN_SOURCE is not defined
4990 #endif
4991 ])
4992 dnl ---------------------------------------------------------------------------
4993 dnl CF__XOPEN_SOURCE_HEAD version: 2 updated: 2023/02/18 17:41:25
4994 dnl ---------------------
4995 dnl headers to include when test-compiling for _XOPEN_SOURCE check
4996 define([CF__XOPEN_SOURCE_HEAD],
4997 [
4998 $ac_includes_default
4999 ])