test/configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2016,2017 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1996-on
  30 dnl
  31 dnl $Id: configure.in,v 1.144 2017/11/25 21:24:23 tom Exp $
  32 dnl This is a simple configuration-script for the ncurses test programs that
  33 dnl allows the test-directory to be separately configured against a reference
  34 dnl system (i.e., sysvr4 curses)
  35 dnl
  36 dnl If you're configuring ncurses, you shouldn't need to use this script.
  37 dnl It's only for testing purposes.
  38 dnl
  39 dnl For additional information, see
  40 dnl             http://invisible-island.net/autoconf/
  41 dnl             http://invisible-island.net/ncurses/ncurses-examples.html
  42 dnl ---------------------------------------------------------------------------
  43 AC_PREREQ(2.52.20170501)
  44 AC_INIT(ncurses.c)
  45 AC_CONFIG_HEADER(ncurses_cfg.h:ncurses_tst.hin)
  46
  47 CF_INHERIT_SCRIPT(config.guess)
  48 CF_INHERIT_SCRIPT(config.sub)
  49 CF_CHECK_CACHE
  50
  51 AC_ARG_PROGRAM
  52
  53 AC_PROG_MAKE_SET
  54 CF_PROG_CC
  55 AC_C_INLINE
  56 AC_PROG_CPP
  57 AC_PROG_AWK
  58 CF_PROG_INSTALL
  59 CF_PROG_LINT
  60 CF_MAKE_TAGS
  61
  62 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
  63 AC_SUBST(MATH_LIB)
  64
  65 dnl Things that we don't need (or must override) if we're not building ncurses
  66 CF_TOP_BUILDDIR
  67 CC_G_OPT="-g"                                   AC_SUBST(CC_G_OPT)
  68 CC_SHARED_OPTS=unknown                  AC_SUBST(CC_SHARED_OPTS)
  69 CPPFLAGS="$CPPFLAGS"                    AC_SUBST(CPPFLAGS)
  70 DFT_DEP_SUFFIX=""                               AC_SUBST(DFT_DEP_SUFFIX)
  71 DFT_OBJ_SUBDIR=`pwd|sed -e's:.*/::'`    AC_SUBST(DFT_OBJ_SUBDIR)
  72 DFT_UPR_MODEL="NORMAL"                  AC_SUBST(DFT_UPR_MODEL)
  73 LD="ld"                                                 AC_SUBST(LD)
  74 LDFLAGS_SHARED=""                               AC_SUBST(LDFLAGS_SHARED)
  75 LDFLAGS_STATIC=""                               AC_SUBST(LDFLAGS_STATIC)
  76 LD_MODEL=""                                             AC_SUBST(LD_MODEL)
  77 LD_SHARED_OPTS=""                               AC_SUBST(LD_SHARED_OPTS)
  78 LIBTOOL=""                                              AC_SUBST(LIBTOOL)
  79 LIBTOOL_OPTS=""                                 AC_SUBST(LIBTOOL_OPTS)
  80 LIB_CLEAN=""                                    AC_SUBST(LIB_CLEAN)
  81 LIB_COMPILE=""                                  AC_SUBST(LIB_COMPILE)
  82 LIB_LINK='${CC}'                                AC_SUBST(LIB_LINK)
  83 LINK_TESTS=""                                   AC_SUBST(LINK_TESTS)
  84 LOCAL_LDFLAGS=""                                AC_SUBST(LOCAL_LDFLAGS)
  85 PACKAGE="ncurses-examples"              AC_SUBST(PACKAGE)
  86 PTHREAD="-lm"                                   AC_SUBST(PTHREAD)
  87 TEST_ARGS=""                                    AC_SUBST(TEST_ARGS)
  88 TEST_DEPS=""                                    AC_SUBST(TEST_DEPS)
  89 TEST_LIBS=""                                    AC_SUBST(TEST_LIBS)
  90 TINFO_LDFLAGS=''                                AC_SUBST(TINFO_LDFLAGS)
  91 TINFO_LIBS='$(LIBS_CURSES)'             AC_SUBST(TINFO_LIBS)
  92 cf_cv_abi_version=""                    AC_SUBST(cf_cv_abi_version)
  93 cf_cv_rel_version=""                    AC_SUBST(cf_cv_rel_version)
  94 includesubdir=""                                AC_SUBST(includesubdir)
  95
  96 cf_cv_screen=curses
  97 cf_cv_libtype=
  98
  99 AC_EXEEXT
 100 AC_OBJEXT
 101
 102 CF_GCC_ATTRIBUTES
 103 CF_ENABLE_STRING_HACKS
 104 CF_XOPEN_SOURCE
 105 CF_SIG_ATOMIC_T
 106
 107 # Work around breakage on OS X
 108 CF_SIGWINCH
 109
 110 # Checks for CODESET support.
 111 AM_LANGINFO_CODESET
 112
 113 dnl ---------------------------------------------------------------------------
 114 CF_HELP_MESSAGE(General Options:)
 115 CF_PKG_CONFIG
 116 CF_DISABLE_ECHO
 117
 118 dnl ---------------------------------------------------------------------------
 119 CF_HELP_MESSAGE(Curses Version-dependent Options:)
 120 CF_NCURSES_WRAP_PREFIX
 121
 122 AC_MSG_CHECKING(if you want to check for wide-character functions)
 123 CF_ARG_DISABLE(widec,
 124         [  --disable-widec         disable checks for wide-character functions],
 125         cf_enable_widec=no,
 126         cf_enable_widec=yes,
 127         yes)
 128 AC_MSG_RESULT($cf_enable_widec)
 129
 130 dnl ---------------------------------------------------------------------------
 131 CF_HELP_MESSAGE(Curses Version-dependent Options:)
 132 CF_WITH_NCURSES_ETC
 133
 134 case $cf_cv_screen in
 135 (ncurses*)
 136         cf_cv_libtype=`echo "$cf_cv_screen" | sed -e 's/^ncurses//'`
 137         ;;
 138 esac
 139
 140 CF_WITH_X11_RGB
 141
 142 dnl If we've not specified a library, assume we're using sysvr4 libraries
 143 dnl installed conventionally (e.g., SunOS 5.x - solaris).
 144
 145 dnl Autoconf builds up the $LIBS in reverse order
 146
 147 cf_curses_headers=
 148
 149 case $cf_cv_screen in
 150 (pdcurses)
 151         cf_default_panel=no
 152         cf_default_form=no
 153         cf_default_menu=no
 154         cf_default_tinfo=no
 155         ;;
 156 (xcurses|bsdcurses)
 157         cf_default_panel=no
 158         cf_default_form=no
 159         cf_default_menu=no
 160         cf_default_tinfo=yes
 161         ;;
 162 (*)
 163         cf_default_panel=yes
 164         cf_default_form=yes
 165         cf_default_menu=yes
 166         cf_default_tinfo=yes
 167         case $cf_cv_screen in
 168         (ncurses*)
 169                 cf_curses_headers="nc_alloc.h nomacros.h term_entry.h"
 170                 ;;
 171         esac
 172         ;;
 173 esac
 174
 175 AC_MSG_CHECKING(if you want to check for panel functions)
 176 CF_ARG_DISABLE(panel,
 177         [  --disable-panel         disable checks for panel functions],
 178         cf_enable_panel=no,
 179         cf_enable_panel=$cf_default_panel,
 180         yes)
 181 AC_MSG_RESULT($cf_enable_panel)
 182 if test $cf_enable_panel = yes
 183 then
 184         CF_CHECK_CURSES_LIB(panel,$cf_cv_libtype,new_panel)
 185         cf_curses_headers="$cf_curses_headers panel.h"
 186 fi
 187
 188 AC_MSG_CHECKING(if you want to check for menu functions)
 189 CF_ARG_DISABLE(menu,
 190         [  --disable-menu          disable checks for menu functions],
 191         cf_enable_menu=no,
 192         cf_enable_menu=$cf_default_menu,
 193         yes)
 194 AC_MSG_RESULT($cf_enable_menu)
 195 if test $cf_enable_menu = yes
 196 then
 197         case $cf_cv_screen in
 198         (ncurses*)
 199                 ;;
 200         (curses*)
 201                 CF_NETBSD_MENU_H
 202                 ;;
 203         esac
 204         CF_CHECK_CURSES_LIB(menu,$cf_cv_libtype,menu_driver)
 205         cf_curses_headers="$cf_curses_headers menu.h"
 206 fi
 207
 208 AC_MSG_CHECKING(if you want to check for form functions)
 209 CF_ARG_DISABLE(form,
 210         [  --disable-form          disable checks for form functions],
 211         cf_enable_form=no,
 212         cf_enable_form=$cf_default_form,
 213         yes)
 214 AC_MSG_RESULT($cf_enable_form)
 215 if test $cf_enable_form = yes
 216 then
 217         case $cf_cv_screen in
 218         (ncurses*)
 219                 ;;
 220         (curses*)
 221                 CF_NETBSD_FORM_H
 222                 ;;
 223         esac
 224         CF_CHECK_CURSES_LIB(form,$cf_cv_libtype,form_driver)
 225         cf_curses_headers="$cf_curses_headers form.h"
 226 fi
 227
 228 # look for curses-related headers
 229 AC_CHECK_HEADERS( $cf_curses_headers )
 230
 231 AC_STDC_HEADERS
 232 AC_HEADER_TIME
 233 AC_CHECK_HEADERS( \
 234 getopt.h \
 235 locale.h \
 236 math.h \
 237 stdarg.h \
 238 stdint.h \
 239 sys/ioctl.h \
 240 sys/select.h \
 241 sys/time.h \
 242 termios.h \
 243 unistd.h \
 244 )
 245
 246 CF_GETOPT_HEADER
 247
 248 AC_CHECK_FUNCS( \
 249 getopt \
 250 gettimeofday \
 251 tdestroy \
 252 tsearch \
 253 )
 254
 255 if test "x$ac_cv_func_getopt" = xno; then
 256         AC_MSG_ERROR(getopt is required for building programs)
 257 fi
 258
 259 if test "$cf_enable_widec" = yes; then
 260 AC_CHECK_FUNCS( \
 261 mblen \
 262 mbrlen \
 263 mbrtowc \
 264 mbsrtowcs \
 265 mbstowcs \
 266 mbtowc \
 267 wcsrtombs \
 268 wcstombs \
 269 )
 270 fi
 271
 272 CF_CURSES_FUNCS( \
 273 alloc_pair \
 274 assume_default_colors \
 275 chgat \
 276 color_content \
 277 color_set \
 278 copywin \
 279 delscreen \
 280 dupwin \
 281 filter \
 282 getbegx \
 283 getcurx \
 284 getmaxx \
 285 getnstr \
 286 getparx \
 287 getwin \
 288 halfdelay \
 289 init_extended_color \
 290 mvderwin \
 291 mvvline \
 292 mvwin \
 293 mvwvline \
 294 napms \
 295 newpad \
 296 putwin \
 297 resize_term \
 298 resizeterm \
 299 restartterm \
 300 ripoffline \
 301 scr_dump \
 302 setupterm \
 303 slk_color \
 304 slk_init \
 305 termattrs \
 306 tgetent \
 307 tigetnum \
 308 tigetstr \
 309 tputs_sp \
 310 typeahead \
 311 use_default_colors \
 312 use_env \
 313 use_extended_names \
 314 use_screen \
 315 use_window \
 316 vid_puts \
 317 vidputs \
 318 vsscanf \
 319 vw_printw \
 320 wchgat \
 321 winsdelln \
 322 winsstr \
 323 wresize \
 324 wsyncdown \
 325 _tracef \
 326 )
 327
 328 CF_TPUTS_PROTO
 329 CF_NCURSES_EXT_FUNCS
 330
 331 if test "$cf_enable_widec" = yes
 332 then
 333         # workaround for systems with ncurses before 20111029, due to change of
 334         # feature test macro from _XPG5 to _XOPEN_SOURCE
 335         if test -n "$cf_cv_ncurses_version" && test "x$cf_cv_ncurses_version" != xno
 336         then
 337                 cf_define_xpg5=no
 338                 AC_MSG_CHECKING(if _XPG5 should be defined to enable wide-characters)
 339
 340                 AC_TRY_COMPILE([
 341 #include <${cf_cv_ncurses_header:-curses.h}>],
 342                         [int x = _XPG5],,
 343                         [cf_save_cppflags="$CPPFLAGS"
 344                          CPPFLAGS="$CPPFLAGS -D_XPG5"
 345                          AC_TRY_COMPILE([
 346 #include <${cf_cv_ncurses_header:-curses.h}>],
 347                                 [int x = _XPG5],
 348                                 [cf_define_xpg5=yes])
 349                          CPPFLAGS="$cf_save_cppflags"])
 350                 AC_MSG_RESULT($cf_define_xpg5)
 351
 352                 if test "$cf_define_xpg5" = yes
 353                 then
 354                         CPPFLAGS="$CPPFLAGS -D_XPG5"
 355                 fi
 356         fi
 357
 358         AC_CACHE_CHECK(for wide-character functions,cf_cv_widechar_funcs,[
 359         AC_TRY_LINK([
 360 #include <${cf_cv_ncurses_header:-curses.h}>],
 361         [
 362                 static wchar_t src_wchar[2];
 363                 static cchar_t dst_cchar;
 364                 setcchar(&dst_cchar, src_wchar, A_NORMAL, 0, (void *) 0);
 365                 ],
 366                 [cf_cv_widechar_funcs=yes],
 367                 [cf_cv_widechar_funcs=no])
 368         ])
 369         if test "$cf_cv_widechar_funcs" != no ; then
 370                 AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to enable wide-character support in (n)curses])
 371         else
 372                 AC_DEFINE(USE_WIDEC_SUPPORT,0)
 373         fi
 374 else
 375         AC_DEFINE(USE_WIDEC_SUPPORT,0)
 376 fi
 377
 378 AC_CACHE_CHECK(if $cf_cv_screen library uses pthreads,cf_cv_use_pthreads,[
 379 AC_TRY_LINK([
 380 #include <${cf_cv_ncurses_header:-curses.h}>
 381 extern void _nc_init_pthreads(void);
 382 ],
 383 [
 384         initscr();
 385         _nc_init_pthreads();
 386         ],
 387         [cf_cv_use_pthreads=yes],
 388         [cf_cv_use_pthreads=no])
 389 ])
 390 test $cf_cv_use_pthreads = yes && AC_DEFINE(USE_PTHREADS)
 391
 392 CF_SYS_TIME_SELECT
 393
 394 # special check for test/ditto.c
 395 CF_FUNC_OPENPTY
 396 if test "$cf_cv_func_openpty" != no ; then
 397         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
 398         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
 399         if test "x$cf_cv_lib_util" = xyes ; then
 400                 CF_ADD_LIB(util,TEST_LIBS)
 401         fi
 402 fi
 403
 404 CF_FUNC_CURSES_VERSION
 405
 406 CF_CURSES_ACS_MAP
 407 if test "$cf_enable_widec" = yes; then
 408         CF_CURSES_WACS_MAP
 409         CF_CURSES_WACS_SYMBOLS
 410 fi
 411
 412 CF_CURSES_CHECK_TYPE(attr_t,long)
 413
 414 if test "$cf_enable_widec" = yes; then
 415         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T, NCURSES_OK_MBSTATE_T)
 416         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 417         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 418
 419         if test "$NCURSES_OK_MBSTATE_T" = 0 ; then
 420                 CF_CURSES_CHECK_TYPE(mbstate_t,long)
 421         fi
 422
 423         if test "$NCURSES_OK_WCHAR_T" = 0 ; then
 424                 CF_CURSES_CHECK_TYPE(wchar_t,long)
 425         fi
 426
 427         if test "$NCURSES_OK_WINT_T" = 0 ; then
 428                 CF_CURSES_CHECK_TYPE(wint_t,long)
 429         fi
 430 fi
 431
 432 CF_CURSES_CHECK_DATA(\
 433 curscr \
 434 ospeed \
 435 boolnames \
 436 boolfnames \
 437 ttytype)
 438
 439 dnl ---------------------------------------------------------------------------
 440 CF_HELP_MESSAGE(Testing/development Options:)
 441 CF_ENABLE_WARNINGS(Wno-unknown-pragmas)
 442 CF_DISABLE_LEAKS
 443 CF_DISABLE_RPATH_HACK
 444
 445 TEST_ARGS="$LIBS"
 446 LIBS=
 447
 448 dnl ---------------------------------------------------------------------------
 449
 450 AC_OUTPUT(Makefile,[
 451 CF_PRG_RULES([$srcdir/mk-test.awk INSTALL=yes ECHO_LINK="$ECHO_LD"], .)
 452         cat >>Makefile <<TEST_EOF
 453
 454 # These rules are generated so we do not rely on suffix rules, which do not
 455 # work consistently for different make-programs (the '\$(MODEL)/' confuses
 456 # some, and the '\$x' confuses others).
 457 TEST_EOF
 458
 459 LIST=`sed -e 's/[[      ]].*//' -e '/^[[#@]]/d' $srcdir/modules`
 460 for N in $LIST
 461 do
 462         cat >>Makefile <<TEST_EOF
 463
 464 \$(MODEL)/$N.o : \$(srcdir)/$N.c \\
 465         \$(srcdir)/test.priv.h \\
 466         ncurses_cfg.h
 467         $SHOW_CC
 468         $ECHO_CC\$(CC) -c \$(CFLAGS_DEFAULT) -DMODULE_NAME="$N" \$(srcdir)/$N.c
 469 TEST_EOF
 470 done
 471
 472 if test -f ../config.guess && test -f ../config.sub
 473 then
 474         cat >>Makefile <<TEST_EOF
 475
 476 # if we used CF_INHERIT for getting these files, we can remove them
 477 distclean::
 478         rm -f config.guess config.sub
 479 TEST_EOF
 480 fi
 481 ],[
 482 AWK="$AWK"
 483 ECHO_CC="$ECHO_CC"
 484 ECHO_LD="$ECHO_LD"
 485 SHOW_CC="$SHOW_LD"
 486 ],cat)