test/configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2016,2017 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1996-on
  30 dnl
  31 dnl $Id: configure.in,v 1.134 2017/08/19 23:40:39 tom Exp $
  32 dnl This is a simple configuration-script for the ncurses test programs that
  33 dnl allows the test-directory to be separately configured against a reference
  34 dnl system (i.e., sysvr4 curses)
  35 dnl
  36 dnl If you're configuring ncurses, you shouldn't need to use this script.
  37 dnl It's only for testing purposes.
  38 dnl
  39 dnl For additional information, see
  40 dnl             http://invisible-island.net/autoconf/
  41 dnl             http://invisible-island.net/ncurses/ncurses-examples.html
  42 dnl ---------------------------------------------------------------------------
  43 AC_PREREQ(2.52.20170501)
  44 AC_INIT(ncurses.c)
  45 AC_CONFIG_HEADER(ncurses_cfg.h:ncurses_tst.hin)
  46
  47 CF_INHERIT_SCRIPT(config.guess)
  48 CF_INHERIT_SCRIPT(config.sub)
  49 CF_CHECK_CACHE
  50
  51 AC_ARG_PROGRAM
  52
  53 AC_PROG_MAKE_SET
  54 CF_PROG_CC
  55 AC_PROG_CPP
  56 AC_PROG_AWK
  57 CF_PROG_INSTALL
  58 CF_PROG_LINT
  59 CF_MAKE_TAGS
  60
  61 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
  62 AC_SUBST(MATH_LIB)
  63
  64 dnl Things that we don't need (or must override) if we're not building ncurses
  65 CF_TOP_BUILDDIR
  66 CC_G_OPT="-g"                                   AC_SUBST(CC_G_OPT)
  67 CC_SHARED_OPTS=unknown                  AC_SUBST(CC_SHARED_OPTS)
  68 CPPFLAGS="$CPPFLAGS"                    AC_SUBST(CPPFLAGS)
  69 DFT_DEP_SUFFIX=""                               AC_SUBST(DFT_DEP_SUFFIX)
  70 DFT_OBJ_SUBDIR=`pwd|sed -e's:.*/::'`    AC_SUBST(DFT_OBJ_SUBDIR)
  71 DFT_UPR_MODEL="NORMAL"                  AC_SUBST(DFT_UPR_MODEL)
  72 LD="ld"                                                 AC_SUBST(LD)
  73 LDFLAGS_SHARED=""                               AC_SUBST(LDFLAGS_SHARED)
  74 LDFLAGS_STATIC=""                               AC_SUBST(LDFLAGS_STATIC)
  75 LD_MODEL=""                                             AC_SUBST(LD_MODEL)
  76 LD_SHARED_OPTS=""                               AC_SUBST(LD_SHARED_OPTS)
  77 LIBTOOL=""                                              AC_SUBST(LIBTOOL)
  78 LIBTOOL_OPTS=""                                 AC_SUBST(LIBTOOL_OPTS)
  79 LIB_CLEAN=""                                    AC_SUBST(LIB_CLEAN)
  80 LIB_COMPILE=""                                  AC_SUBST(LIB_COMPILE)
  81 LIB_LINK='${CC}'                                AC_SUBST(LIB_LINK)
  82 LINK_TESTS=""                                   AC_SUBST(LINK_TESTS)
  83 LOCAL_LDFLAGS=""                                AC_SUBST(LOCAL_LDFLAGS)
  84 PACKAGE="ncurses-examples"              AC_SUBST(PACKAGE)
  85 PTHREAD="-lm"                                   AC_SUBST(PTHREAD)
  86 TEST_ARGS=""                                    AC_SUBST(TEST_ARGS)
  87 TEST_DEPS=""                                    AC_SUBST(TEST_DEPS)
  88 TEST_LIBS=""                                    AC_SUBST(TEST_LIBS)
  89 TINFO_LDFLAGS=''                                AC_SUBST(TINFO_LDFLAGS)
  90 TINFO_LIBS='$(LIBS_CURSES)'             AC_SUBST(TINFO_LIBS)
  91 cf_cv_abi_version=""                    AC_SUBST(cf_cv_abi_version)
  92 cf_cv_rel_version=""                    AC_SUBST(cf_cv_rel_version)
  93 includesubdir=""                                AC_SUBST(includesubdir)
  94
  95 cf_cv_screen=curses
  96 cf_cv_libtype=
  97
  98 AC_EXEEXT
  99 AC_OBJEXT
 100
 101 CF_GCC_ATTRIBUTES
 102 CF_ENABLE_STRING_HACKS
 103 CF_XOPEN_SOURCE
 104 CF_SIG_ATOMIC_T
 105
 106 # Work around breakage on OS X
 107 CF_SIGWINCH
 108
 109 # Checks for CODESET support.
 110 AM_LANGINFO_CODESET
 111
 112 dnl ---------------------------------------------------------------------------
 113 CF_HELP_MESSAGE(General Options:)
 114 CF_PKG_CONFIG
 115 CF_DISABLE_ECHO
 116
 117 dnl ---------------------------------------------------------------------------
 118 CF_HELP_MESSAGE(Curses Version-dependent Options:)
 119 CF_NCURSES_WRAP_PREFIX
 120
 121 AC_MSG_CHECKING(if you want to check for wide-character functions)
 122 CF_ARG_DISABLE(widec,
 123         [  --disable-widec         disable checks for wide-character functions],
 124         cf_enable_widec=no,
 125         cf_enable_widec=yes,
 126         yes)
 127 AC_MSG_RESULT($cf_enable_widec)
 128
 129 dnl ---------------------------------------------------------------------------
 130 CF_HELP_MESSAGE(Curses Version-dependent Options:)
 131 CF_WITH_NCURSES_ETC
 132
 133 case $cf_cv_screen in
 134 (ncurses*)
 135         cf_cv_libtype=`echo "$cf_cv_screen" | sed -e 's/^ncurses//'`
 136         ;;
 137 (curses|curses_*)
 138         CF_NETBSD_FORM_H
 139         CF_NETBSD_MENU_H
 140         ;;
 141 esac
 142
 143 dnl If we've not specified a library, assume we're using sysvr4 libraries
 144 dnl installed conventionally (e.g., SunOS 5.x - solaris).
 145
 146 dnl Autoconf builds up the $LIBS in reverse order
 147
 148 case $cf_cv_screen in
 149 (pdcurses)
 150         ;;
 151 (*)
 152         # look for curses-related libraries
 153         CF_CHECK_CURSES_LIB(panel,$cf_cv_libtype,new_panel)
 154         CF_CHECK_CURSES_LIB(menu,$cf_cv_libtype,menu_driver)
 155         CF_CHECK_CURSES_LIB(form,$cf_cv_libtype,form_driver)
 156
 157         # look for curses-related headers
 158         AC_CHECK_HEADERS( \
 159                 nc_alloc.h \
 160                 nomacros.h \
 161                 form.h \
 162                 menu.h \
 163                 panel.h \
 164                 term_entry.h \
 165                 )
 166         ;;
 167 esac
 168
 169 AC_STDC_HEADERS
 170 AC_HEADER_TIME
 171 AC_CHECK_HEADERS( \
 172 getopt.h \
 173 locale.h \
 174 math.h \
 175 stdarg.h \
 176 stdint.h \
 177 sys/ioctl.h \
 178 sys/select.h \
 179 sys/time.h \
 180 termios.h \
 181 unistd.h \
 182 )
 183
 184 CF_GETOPT_HEADER
 185
 186 AC_CHECK_FUNCS( \
 187 getopt \
 188 gettimeofday \
 189 tdestroy \
 190 tsearch \
 191 )
 192
 193 if test "x$ac_cv_func_getopt" = xno; then
 194         AC_MSG_ERROR(getopt is required for building programs)
 195 fi
 196
 197 if test "$cf_enable_widec" = yes; then
 198 AC_CHECK_FUNCS( \
 199 mblen \
 200 mbrlen \
 201 mbrtowc \
 202 mbsrtowcs \
 203 mbstowcs \
 204 mbtowc \
 205 wcsrtombs \
 206 wcstombs \
 207 )
 208 fi
 209
 210 CF_CURSES_FUNCS( \
 211 alloc_pair \
 212 assume_default_colors \
 213 chgat \
 214 color_set \
 215 filter \
 216 getbegx \
 217 getcurx \
 218 getmaxx \
 219 getnstr \
 220 getparx \
 221 getwin \
 222 init_extended_color \
 223 mvvline \
 224 mvwvline \
 225 napms \
 226 putwin \
 227 resize_term \
 228 resizeterm \
 229 restartterm \
 230 ripoffline \
 231 scr_dump \
 232 setupterm \
 233 slk_color \
 234 slk_init \
 235 termattrs \
 236 tgetent \
 237 tigetnum \
 238 tigetstr \
 239 tputs_sp \
 240 typeahead \
 241 use_default_colors \
 242 use_env \
 243 use_extended_names \
 244 use_screen \
 245 use_window \
 246 vid_puts \
 247 vidputs \
 248 vsscanf \
 249 vw_printw \
 250 wchgat \
 251 winsstr \
 252 wresize \
 253 wsyncdown \
 254 _tracef \
 255 )
 256
 257 CF_TPUTS_PROTO
 258 CF_NCURSES_EXT_FUNCS
 259
 260 if test "$cf_enable_widec" = yes
 261 then
 262         # workaround for systems with ncurses before 20111029, due to change of
 263         # feature test macro from _XPG5 to _XOPEN_SOURCE
 264         if test -n "$cf_cv_ncurses_version" && test "x$cf_cv_ncurses_version" != xno
 265         then
 266                 cf_define_xpg5=no
 267                 AC_MSG_CHECKING(if _XPG5 should be defined to enable wide-characters)
 268
 269                 AC_TRY_COMPILE([
 270 #include <${cf_cv_ncurses_header:-curses.h}>],
 271                         [int x = _XPG5],,
 272                         [cf_save_cppflags="$CPPFLAGS"
 273                          CPPFLAGS="$CPPFLAGS -D_XPG5"
 274                          AC_TRY_COMPILE([
 275 #include <${cf_cv_ncurses_header:-curses.h}>],
 276                                 [int x = _XPG5],
 277                                 [cf_define_xpg5=yes])
 278                          CPPFLAGS="$cf_save_cppflags"])
 279                 AC_MSG_RESULT($cf_define_xpg5)
 280
 281                 if test "$cf_define_xpg5" = yes
 282                 then
 283                         CPPFLAGS="$CPPFLAGS -D_XPG5"
 284                 fi
 285         fi
 286
 287         AC_CACHE_CHECK(for wide-character functions,cf_cv_widechar_funcs,[
 288         AC_TRY_LINK([
 289 #include <${cf_cv_ncurses_header:-curses.h}>],
 290         [
 291                 static wchar_t src_wchar[2];
 292                 static cchar_t dst_cchar;
 293                 setcchar(&dst_cchar, src_wchar, A_NORMAL, 0, (void *) 0);
 294                 ],
 295                 [cf_cv_widechar_funcs=yes],
 296                 [cf_cv_widechar_funcs=no])
 297         ])
 298         if test "$cf_cv_widechar_funcs" != no ; then
 299                 AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to enable wide-character support in (n)curses])
 300         else
 301                 AC_DEFINE(USE_WIDEC_SUPPORT,0)
 302         fi
 303 else
 304         AC_DEFINE(USE_WIDEC_SUPPORT,0)
 305 fi
 306
 307 AC_CACHE_CHECK(if $cf_cv_screen library uses pthreads,cf_cv_use_pthreads,[
 308 AC_TRY_LINK([
 309 #include <${cf_cv_ncurses_header:-curses.h}>
 310 extern void _nc_init_pthreads(void);
 311 ],
 312 [
 313         initscr();
 314         _nc_init_pthreads();
 315         ],
 316         [cf_cv_use_pthreads=yes],
 317         [cf_cv_use_pthreads=no])
 318 ])
 319 test $cf_cv_use_pthreads = yes && AC_DEFINE(USE_PTHREADS)
 320
 321 CF_SYS_TIME_SELECT
 322
 323 # special check for test/ditto.c
 324 CF_FUNC_OPENPTY
 325 if test "$cf_cv_func_openpty" != no ; then
 326         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
 327         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
 328         if test "x$cf_cv_lib_util" = xyes ; then
 329                 CF_ADD_LIB(util,TEST_LIBS)
 330         fi
 331 fi
 332
 333 CF_FUNC_CURSES_VERSION
 334
 335 CF_CURSES_ACS_MAP
 336 if test "$cf_enable_widec" = yes; then
 337         CF_CURSES_WACS_MAP
 338         CF_CURSES_WACS_SYMBOLS
 339 fi
 340
 341 CF_CURSES_CHECK_TYPE(attr_t,long)
 342
 343 if test "$cf_enable_widec" = yes; then
 344         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T, NCURSES_OK_MBSTATE_T)
 345         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 346         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 347
 348         if test "$NCURSES_OK_MBSTATE_T" = 0 ; then
 349                 CF_CURSES_CHECK_TYPE(mbstate_t,long)
 350         fi
 351
 352         if test "$NCURSES_OK_WCHAR_T" = 0 ; then
 353                 CF_CURSES_CHECK_TYPE(wchar_t,long)
 354         fi
 355
 356         if test "$NCURSES_OK_WINT_T" = 0 ; then
 357                 CF_CURSES_CHECK_TYPE(wint_t,long)
 358         fi
 359 fi
 360
 361 CF_CURSES_CHECK_DATA(ospeed)
 362 CF_CURSES_CHECK_DATA(boolnames)
 363 CF_CURSES_CHECK_DATA(boolfnames)
 364 CF_CURSES_CHECK_DATA(ttytype)
 365
 366 dnl ---------------------------------------------------------------------------
 367 CF_HELP_MESSAGE(Testing/development Options:)
 368 CF_ENABLE_WARNINGS
 369 CF_DISABLE_LEAKS
 370 CF_DISABLE_RPATH_HACK
 371
 372 TEST_ARGS="$LIBS"
 373 LIBS=
 374
 375 dnl ---------------------------------------------------------------------------
 376
 377 AC_OUTPUT(Makefile,[
 378 CF_PRG_RULES([$srcdir/mk-test.awk INSTALL=yes ECHO_LINK="$ECHO_LD"], .)
 379         cat >>Makefile <<TEST_EOF
 380
 381 # These rules are generated so we do not rely on suffix rules, which do not
 382 # work consistently for different make-programs (the '\$(MODEL)/' confuses
 383 # some, and the '\$x' confuses others).
 384 TEST_EOF
 385
 386 LIST=`sed -e 's/[[      ]].*//' -e '/^[[#@]]/d' $srcdir/modules`
 387 for N in $LIST
 388 do
 389         cat >>Makefile <<TEST_EOF
 390
 391 \$(MODEL)/$N.o : \$(srcdir)/$N.c \\
 392         \$(srcdir)/test.priv.h \\
 393         ncurses_cfg.h
 394         $SHOW_CC
 395         $ECHO_CC\$(CC) -c \$(CFLAGS_DEFAULT) \$(srcdir)/$N.c
 396 TEST_EOF
 397 done
 398
 399 if test -f ../config.guess && test -f ../config.sub
 400 then
 401         cat >>Makefile <<TEST_EOF
 402
 403 # if we used CF_INHERIT for getting these files, we can remove them
 404 distclean::
 405         rm -f config.guess config.sub
 406 TEST_EOF
 407 fi
 408 ],[
 409 AWK="$AWK"
 410 ECHO_CC="$ECHO_CC"
 411 ECHO_LD="$ECHO_LD"
 412 SHOW_CC="$SHOW_LD"
 413 ],cat)