test/configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2016,2017 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1996-on
  30 dnl
  31 dnl $Id: configure.in,v 1.142 2017/09/09 23:07:56 tom Exp $
  32 dnl This is a simple configuration-script for the ncurses test programs that
  33 dnl allows the test-directory to be separately configured against a reference
  34 dnl system (i.e., sysvr4 curses)
  35 dnl
  36 dnl If you're configuring ncurses, you shouldn't need to use this script.
  37 dnl It's only for testing purposes.
  38 dnl
  39 dnl For additional information, see
  40 dnl             http://invisible-island.net/autoconf/
  41 dnl             http://invisible-island.net/ncurses/ncurses-examples.html
  42 dnl ---------------------------------------------------------------------------
  43 AC_PREREQ(2.52.20170501)
  44 AC_INIT(ncurses.c)
  45 AC_CONFIG_HEADER(ncurses_cfg.h:ncurses_tst.hin)
  46
  47 CF_INHERIT_SCRIPT(config.guess)
  48 CF_INHERIT_SCRIPT(config.sub)
  49 CF_CHECK_CACHE
  50
  51 AC_ARG_PROGRAM
  52
  53 AC_PROG_MAKE_SET
  54 CF_PROG_CC
  55 AC_C_INLINE
  56 AC_PROG_CPP
  57 AC_PROG_AWK
  58 CF_PROG_INSTALL
  59 CF_PROG_LINT
  60 CF_MAKE_TAGS
  61
  62 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
  63 AC_SUBST(MATH_LIB)
  64
  65 dnl Things that we don't need (or must override) if we're not building ncurses
  66 CF_TOP_BUILDDIR
  67 CC_G_OPT="-g"                                   AC_SUBST(CC_G_OPT)
  68 CC_SHARED_OPTS=unknown                  AC_SUBST(CC_SHARED_OPTS)
  69 CPPFLAGS="$CPPFLAGS"                    AC_SUBST(CPPFLAGS)
  70 DFT_DEP_SUFFIX=""                               AC_SUBST(DFT_DEP_SUFFIX)
  71 DFT_OBJ_SUBDIR=`pwd|sed -e's:.*/::'`    AC_SUBST(DFT_OBJ_SUBDIR)
  72 DFT_UPR_MODEL="NORMAL"                  AC_SUBST(DFT_UPR_MODEL)
  73 LD="ld"                                                 AC_SUBST(LD)
  74 LDFLAGS_SHARED=""                               AC_SUBST(LDFLAGS_SHARED)
  75 LDFLAGS_STATIC=""                               AC_SUBST(LDFLAGS_STATIC)
  76 LD_MODEL=""                                             AC_SUBST(LD_MODEL)
  77 LD_SHARED_OPTS=""                               AC_SUBST(LD_SHARED_OPTS)
  78 LIBTOOL=""                                              AC_SUBST(LIBTOOL)
  79 LIBTOOL_OPTS=""                                 AC_SUBST(LIBTOOL_OPTS)
  80 LIB_CLEAN=""                                    AC_SUBST(LIB_CLEAN)
  81 LIB_COMPILE=""                                  AC_SUBST(LIB_COMPILE)
  82 LIB_LINK='${CC}'                                AC_SUBST(LIB_LINK)
  83 LINK_TESTS=""                                   AC_SUBST(LINK_TESTS)
  84 LOCAL_LDFLAGS=""                                AC_SUBST(LOCAL_LDFLAGS)
  85 PACKAGE="ncurses-examples"              AC_SUBST(PACKAGE)
  86 PTHREAD="-lm"                                   AC_SUBST(PTHREAD)
  87 TEST_ARGS=""                                    AC_SUBST(TEST_ARGS)
  88 TEST_DEPS=""                                    AC_SUBST(TEST_DEPS)
  89 TEST_LIBS=""                                    AC_SUBST(TEST_LIBS)
  90 TINFO_LDFLAGS=''                                AC_SUBST(TINFO_LDFLAGS)
  91 TINFO_LIBS='$(LIBS_CURSES)'             AC_SUBST(TINFO_LIBS)
  92 cf_cv_abi_version=""                    AC_SUBST(cf_cv_abi_version)
  93 cf_cv_rel_version=""                    AC_SUBST(cf_cv_rel_version)
  94 includesubdir=""                                AC_SUBST(includesubdir)
  95
  96 cf_cv_screen=curses
  97 cf_cv_libtype=
  98
  99 AC_EXEEXT
 100 AC_OBJEXT
 101
 102 CF_GCC_ATTRIBUTES
 103 CF_ENABLE_STRING_HACKS
 104 CF_XOPEN_SOURCE
 105 CF_SIG_ATOMIC_T
 106
 107 # Work around breakage on OS X
 108 CF_SIGWINCH
 109
 110 # Checks for CODESET support.
 111 AM_LANGINFO_CODESET
 112
 113 dnl ---------------------------------------------------------------------------
 114 CF_HELP_MESSAGE(General Options:)
 115 CF_PKG_CONFIG
 116 CF_DISABLE_ECHO
 117
 118 dnl ---------------------------------------------------------------------------
 119 CF_HELP_MESSAGE(Curses Version-dependent Options:)
 120 CF_NCURSES_WRAP_PREFIX
 121
 122 AC_MSG_CHECKING(if you want to check for wide-character functions)
 123 CF_ARG_DISABLE(widec,
 124         [  --disable-widec         disable checks for wide-character functions],
 125         cf_enable_widec=no,
 126         cf_enable_widec=yes,
 127         yes)
 128 AC_MSG_RESULT($cf_enable_widec)
 129
 130 dnl ---------------------------------------------------------------------------
 131 CF_HELP_MESSAGE(Curses Version-dependent Options:)
 132 CF_WITH_NCURSES_ETC
 133
 134 case $cf_cv_screen in
 135 (ncurses*)
 136         cf_cv_libtype=`echo "$cf_cv_screen" | sed -e 's/^ncurses//'`
 137         ;;
 138 esac
 139
 140 dnl If we've not specified a library, assume we're using sysvr4 libraries
 141 dnl installed conventionally (e.g., SunOS 5.x - solaris).
 142
 143 dnl Autoconf builds up the $LIBS in reverse order
 144
 145 cf_curses_headers=
 146
 147 case $cf_cv_screen in
 148 (pdcurses)
 149         cf_default_panel=no
 150         cf_default_form=no
 151         cf_default_menu=no
 152         cf_default_tinfo=no
 153         ;;
 154 (xcurses|bsdcurses)
 155         cf_default_panel=no
 156         cf_default_form=no
 157         cf_default_menu=no
 158         cf_default_tinfo=yes
 159         ;;
 160 (*)
 161         cf_default_panel=yes
 162         cf_default_form=yes
 163         cf_default_menu=yes
 164         cf_default_tinfo=yes
 165         case $cf_cv_screen in
 166         (ncurses*)
 167                 cf_curses_headers="nc_alloc.h nomacros.h term_entry.h"
 168                 ;;
 169         esac
 170         ;;
 171 esac
 172
 173 AC_MSG_CHECKING(if you want to check for panel functions)
 174 CF_ARG_DISABLE(panel,
 175         [  --disable-panel         disable checks for panel functions],
 176         cf_enable_panel=no,
 177         cf_enable_panel=$cf_default_panel,
 178         yes)
 179 AC_MSG_RESULT($cf_enable_panel)
 180 if test $cf_enable_panel = yes
 181 then
 182         CF_CHECK_CURSES_LIB(panel,$cf_cv_libtype,new_panel)
 183         cf_curses_headers="$cf_curses_headers panel.h"
 184 fi
 185
 186 AC_MSG_CHECKING(if you want to check for menu functions)
 187 CF_ARG_DISABLE(menu,
 188         [  --disable-menu          disable checks for menu functions],
 189         cf_enable_menu=no,
 190         cf_enable_menu=$cf_default_menu,
 191         yes)
 192 AC_MSG_RESULT($cf_enable_menu)
 193 if test $cf_enable_menu = yes
 194 then
 195         case $cf_cv_screen in
 196         (ncurses*)
 197                 ;;
 198         (curses*)
 199                 CF_NETBSD_MENU_H
 200                 ;;
 201         esac
 202         CF_CHECK_CURSES_LIB(menu,$cf_cv_libtype,menu_driver)
 203         cf_curses_headers="$cf_curses_headers menu.h"
 204 fi
 205
 206 AC_MSG_CHECKING(if you want to check for form functions)
 207 CF_ARG_DISABLE(form,
 208         [  --disable-form          disable checks for form functions],
 209         cf_enable_form=no,
 210         cf_enable_form=$cf_default_form,
 211         yes)
 212 AC_MSG_RESULT($cf_enable_form)
 213 if test $cf_enable_form = yes
 214 then
 215         case $cf_cv_screen in
 216         (ncurses*)
 217                 ;;
 218         (curses*)
 219                 CF_NETBSD_FORM_H
 220                 ;;
 221         esac
 222         CF_CHECK_CURSES_LIB(form,$cf_cv_libtype,form_driver)
 223         cf_curses_headers="$cf_curses_headers form.h"
 224 fi
 225
 226 # look for curses-related headers
 227 AC_CHECK_HEADERS( $cf_curses_headers )
 228
 229 AC_STDC_HEADERS
 230 AC_HEADER_TIME
 231 AC_CHECK_HEADERS( \
 232 getopt.h \
 233 locale.h \
 234 math.h \
 235 stdarg.h \
 236 stdint.h \
 237 sys/ioctl.h \
 238 sys/select.h \
 239 sys/time.h \
 240 termios.h \
 241 unistd.h \
 242 )
 243
 244 CF_GETOPT_HEADER
 245
 246 AC_CHECK_FUNCS( \
 247 getopt \
 248 gettimeofday \
 249 tdestroy \
 250 tsearch \
 251 )
 252
 253 if test "x$ac_cv_func_getopt" = xno; then
 254         AC_MSG_ERROR(getopt is required for building programs)
 255 fi
 256
 257 if test "$cf_enable_widec" = yes; then
 258 AC_CHECK_FUNCS( \
 259 mblen \
 260 mbrlen \
 261 mbrtowc \
 262 mbsrtowcs \
 263 mbstowcs \
 264 mbtowc \
 265 wcsrtombs \
 266 wcstombs \
 267 )
 268 fi
 269
 270 CF_CURSES_FUNCS( \
 271 alloc_pair \
 272 assume_default_colors \
 273 chgat \
 274 color_content \
 275 color_set \
 276 copywin \
 277 delscreen \
 278 dupwin \
 279 filter \
 280 getbegx \
 281 getcurx \
 282 getmaxx \
 283 getnstr \
 284 getparx \
 285 getwin \
 286 halfdelay \
 287 init_extended_color \
 288 mvderwin \
 289 mvvline \
 290 mvwin \
 291 mvwvline \
 292 napms \
 293 newpad \
 294 putwin \
 295 resize_term \
 296 resizeterm \
 297 restartterm \
 298 ripoffline \
 299 scr_dump \
 300 setupterm \
 301 slk_color \
 302 slk_init \
 303 termattrs \
 304 tgetent \
 305 tigetnum \
 306 tigetstr \
 307 tputs_sp \
 308 typeahead \
 309 use_default_colors \
 310 use_env \
 311 use_extended_names \
 312 use_screen \
 313 use_window \
 314 vid_puts \
 315 vidputs \
 316 vsscanf \
 317 vw_printw \
 318 wchgat \
 319 winsdelln \
 320 winsstr \
 321 wresize \
 322 wsyncdown \
 323 _tracef \
 324 )
 325
 326 CF_TPUTS_PROTO
 327 CF_NCURSES_EXT_FUNCS
 328
 329 if test "$cf_enable_widec" = yes
 330 then
 331         # workaround for systems with ncurses before 20111029, due to change of
 332         # feature test macro from _XPG5 to _XOPEN_SOURCE
 333         if test -n "$cf_cv_ncurses_version" && test "x$cf_cv_ncurses_version" != xno
 334         then
 335                 cf_define_xpg5=no
 336                 AC_MSG_CHECKING(if _XPG5 should be defined to enable wide-characters)
 337
 338                 AC_TRY_COMPILE([
 339 #include <${cf_cv_ncurses_header:-curses.h}>],
 340                         [int x = _XPG5],,
 341                         [cf_save_cppflags="$CPPFLAGS"
 342                          CPPFLAGS="$CPPFLAGS -D_XPG5"
 343                          AC_TRY_COMPILE([
 344 #include <${cf_cv_ncurses_header:-curses.h}>],
 345                                 [int x = _XPG5],
 346                                 [cf_define_xpg5=yes])
 347                          CPPFLAGS="$cf_save_cppflags"])
 348                 AC_MSG_RESULT($cf_define_xpg5)
 349
 350                 if test "$cf_define_xpg5" = yes
 351                 then
 352                         CPPFLAGS="$CPPFLAGS -D_XPG5"
 353                 fi
 354         fi
 355
 356         AC_CACHE_CHECK(for wide-character functions,cf_cv_widechar_funcs,[
 357         AC_TRY_LINK([
 358 #include <${cf_cv_ncurses_header:-curses.h}>],
 359         [
 360                 static wchar_t src_wchar[2];
 361                 static cchar_t dst_cchar;
 362                 setcchar(&dst_cchar, src_wchar, A_NORMAL, 0, (void *) 0);
 363                 ],
 364                 [cf_cv_widechar_funcs=yes],
 365                 [cf_cv_widechar_funcs=no])
 366         ])
 367         if test "$cf_cv_widechar_funcs" != no ; then
 368                 AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to enable wide-character support in (n)curses])
 369         else
 370                 AC_DEFINE(USE_WIDEC_SUPPORT,0)
 371         fi
 372 else
 373         AC_DEFINE(USE_WIDEC_SUPPORT,0)
 374 fi
 375
 376 AC_CACHE_CHECK(if $cf_cv_screen library uses pthreads,cf_cv_use_pthreads,[
 377 AC_TRY_LINK([
 378 #include <${cf_cv_ncurses_header:-curses.h}>
 379 extern void _nc_init_pthreads(void);
 380 ],
 381 [
 382         initscr();
 383         _nc_init_pthreads();
 384         ],
 385         [cf_cv_use_pthreads=yes],
 386         [cf_cv_use_pthreads=no])
 387 ])
 388 test $cf_cv_use_pthreads = yes && AC_DEFINE(USE_PTHREADS)
 389
 390 CF_SYS_TIME_SELECT
 391
 392 # special check for test/ditto.c
 393 CF_FUNC_OPENPTY
 394 if test "$cf_cv_func_openpty" != no ; then
 395         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
 396         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
 397         if test "x$cf_cv_lib_util" = xyes ; then
 398                 CF_ADD_LIB(util,TEST_LIBS)
 399         fi
 400 fi
 401
 402 CF_FUNC_CURSES_VERSION
 403
 404 CF_CURSES_ACS_MAP
 405 if test "$cf_enable_widec" = yes; then
 406         CF_CURSES_WACS_MAP
 407         CF_CURSES_WACS_SYMBOLS
 408 fi
 409
 410 CF_CURSES_CHECK_TYPE(attr_t,long)
 411
 412 if test "$cf_enable_widec" = yes; then
 413         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T, NCURSES_OK_MBSTATE_T)
 414         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 415         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 416
 417         if test "$NCURSES_OK_MBSTATE_T" = 0 ; then
 418                 CF_CURSES_CHECK_TYPE(mbstate_t,long)
 419         fi
 420
 421         if test "$NCURSES_OK_WCHAR_T" = 0 ; then
 422                 CF_CURSES_CHECK_TYPE(wchar_t,long)
 423         fi
 424
 425         if test "$NCURSES_OK_WINT_T" = 0 ; then
 426                 CF_CURSES_CHECK_TYPE(wint_t,long)
 427         fi
 428 fi
 429
 430 CF_CURSES_CHECK_DATA(curscr)
 431 CF_CURSES_CHECK_DATA(ospeed)
 432 CF_CURSES_CHECK_DATA(boolnames)
 433 CF_CURSES_CHECK_DATA(boolfnames)
 434 CF_CURSES_CHECK_DATA(ttytype)
 435
 436 dnl ---------------------------------------------------------------------------
 437 CF_HELP_MESSAGE(Testing/development Options:)
 438 CF_ENABLE_WARNINGS
 439 CF_DISABLE_LEAKS
 440 CF_DISABLE_RPATH_HACK
 441
 442 TEST_ARGS="$LIBS"
 443 LIBS=
 444
 445 dnl ---------------------------------------------------------------------------
 446
 447 AC_OUTPUT(Makefile,[
 448 CF_PRG_RULES([$srcdir/mk-test.awk INSTALL=yes ECHO_LINK="$ECHO_LD"], .)
 449         cat >>Makefile <<TEST_EOF
 450
 451 # These rules are generated so we do not rely on suffix rules, which do not
 452 # work consistently for different make-programs (the '\$(MODEL)/' confuses
 453 # some, and the '\$x' confuses others).
 454 TEST_EOF
 455
 456 LIST=`sed -e 's/[[      ]].*//' -e '/^[[#@]]/d' $srcdir/modules`
 457 for N in $LIST
 458 do
 459         cat >>Makefile <<TEST_EOF
 460
 461 \$(MODEL)/$N.o : \$(srcdir)/$N.c \\
 462         \$(srcdir)/test.priv.h \\
 463         ncurses_cfg.h
 464         $SHOW_CC
 465         $ECHO_CC\$(CC) -c \$(CFLAGS_DEFAULT) -DMODULE_NAME="$N" \$(srcdir)/$N.c
 466 TEST_EOF
 467 done
 468
 469 if test -f ../config.guess && test -f ../config.sub
 470 then
 471         cat >>Makefile <<TEST_EOF
 472
 473 # if we used CF_INHERIT for getting these files, we can remove them
 474 distclean::
 475         rm -f config.guess config.sub
 476 TEST_EOF
 477 fi
 478 ],[
 479 AWK="$AWK"
 480 ECHO_CC="$ECHO_CC"
 481 ECHO_LD="$ECHO_LD"
 482 SHOW_CC="$SHOW_LD"
 483 ],cat)