ncurses 6.0 - patch 20160618
[ncurses.git] / test / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2015,2016 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1996, etc.
30 dnl
31 dnl $Id: configure.in,v 1.127 2016/06/18 23:50:44 tom Exp $
32 dnl This is a simple configuration-script for the ncurses test programs that
33 dnl allows the test-directory to be separately configured against a reference
34 dnl system (i.e., sysvr4 curses)
35 dnl
36 dnl If you're configuring ncurses, you shouldn't need to use this script.
37 dnl It's only for testing purposes.
38 dnl
39 dnl See http://invisible-island.net/autoconf/ for additional information.
40 dnl ---------------------------------------------------------------------------
41 AC_PREREQ(2.52.20030208)
42 AC_INIT(ncurses.c)
43 AC_CONFIG_HEADER(ncurses_cfg.h:ncurses_tst.hin)
44
45 CF_INHERIT_SCRIPT(config.guess)
46 CF_INHERIT_SCRIPT(config.sub)
47 CF_CHECK_CACHE
48
49 AC_ARG_PROGRAM
50
51 AC_PROG_MAKE_SET
52 CF_PROG_CC
53 AC_PROG_CPP
54 AC_PROG_AWK
55 CF_PROG_INSTALL
56 CF_PROG_LINT
57 CF_MAKE_TAGS
58
59 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
60 AC_SUBST(MATH_LIB)
61
62 dnl Things that we don't need (or must override) if we're not building ncurses
63 CF_TOP_BUILDDIR
64 CC_G_OPT="-g"                                   AC_SUBST(CC_G_OPT)
65 CC_SHARED_OPTS=unknown                  AC_SUBST(CC_SHARED_OPTS)
66 CPPFLAGS="$CPPFLAGS"                    AC_SUBST(CPPFLAGS)
67 DFT_DEP_SUFFIX=""                               AC_SUBST(DFT_DEP_SUFFIX)
68 DFT_OBJ_SUBDIR=`pwd|sed -e's:.*/::'`    AC_SUBST(DFT_OBJ_SUBDIR)
69 DFT_UPR_MODEL="NORMAL"                  AC_SUBST(DFT_UPR_MODEL)
70 LD="ld"                                                 AC_SUBST(LD)
71 LDFLAGS_SHARED=""                               AC_SUBST(LDFLAGS_SHARED)
72 LDFLAGS_STATIC=""                               AC_SUBST(LDFLAGS_STATIC)
73 LD_MODEL=""                                             AC_SUBST(LD_MODEL)
74 LD_SHARED_OPTS=""                               AC_SUBST(LD_SHARED_OPTS)
75 LIBTOOL=""                                              AC_SUBST(LIBTOOL)
76 LIBTOOL_OPTS=""                                 AC_SUBST(LIBTOOL_OPTS)
77 LIB_CLEAN=""                                    AC_SUBST(LIB_CLEAN)
78 LIB_COMPILE=""                                  AC_SUBST(LIB_COMPILE)
79 LIB_LINK='${CC}'                                AC_SUBST(LIB_LINK)
80 LINK_TESTS=""                                   AC_SUBST(LINK_TESTS)
81 LOCAL_LDFLAGS=""                                AC_SUBST(LOCAL_LDFLAGS)
82 PACKAGE="ncurses-examples"              AC_SUBST(PACKAGE)
83 PTHREAD="-lm"                                   AC_SUBST(PTHREAD)
84 TEST_ARGS=""                                    AC_SUBST(TEST_ARGS)
85 TEST_DEPS=""                                    AC_SUBST(TEST_DEPS)
86 TEST_LIBS=""                                    AC_SUBST(TEST_LIBS)
87 TINFO_LDFLAGS=''                                AC_SUBST(TINFO_LDFLAGS)
88 TINFO_LIBS='$(LIBS_CURSES)'             AC_SUBST(TINFO_LIBS)
89 cf_cv_abi_version=""                    AC_SUBST(cf_cv_abi_version)
90 cf_cv_rel_version=""                    AC_SUBST(cf_cv_rel_version)
91 includesubdir=""                                AC_SUBST(includesubdir)
92
93 cf_cv_screen=curses
94 cf_cv_libtype=
95
96 AC_EXEEXT
97 AC_OBJEXT
98
99 CF_GCC_ATTRIBUTES
100 CF_XOPEN_SOURCE
101 CF_SIG_ATOMIC_T
102
103 # Work around breakage on OS X
104 CF_SIGWINCH
105
106 # Checks for CODESET support.
107 AM_LANGINFO_CODESET
108
109 dnl ---------------------------------------------------------------------------
110 CF_HELP_MESSAGE(General Options:)
111 CF_PKG_CONFIG
112 CF_DISABLE_ECHO
113
114 dnl ---------------------------------------------------------------------------
115 CF_HELP_MESSAGE(Curses Version-dependent Options:)
116 CF_NCURSES_WRAP_PREFIX
117
118 AC_MSG_CHECKING(if you want to check for wide-character functions)
119 CF_ARG_DISABLE(widec,
120         [  --disable-widec         disable checks for wide-character functions],
121         cf_enable_widec=no,
122         cf_enable_widec=yes,
123         yes)
124 AC_MSG_RESULT($cf_enable_widec)
125
126 dnl ---------------------------------------------------------------------------
127 CF_HELP_MESSAGE(Curses Version-dependent Options:)
128 CF_WITH_NCURSES_ETC
129
130 case $cf_cv_screen in
131 (ncurses*)
132         cf_cv_libtype=`echo "$cf_cv_screen" | sed -e 's/^ncurses//'`
133         ;;
134 (curses|curses_*)
135         CF_NETBSD_FORM_H
136         CF_NETBSD_MENU_H
137         ;;
138 esac
139
140 dnl If we've not specified a library, assume we're using sysvr4 libraries
141 dnl installed conventionally (e.g., SunOS 5.x - solaris).
142
143 dnl Autoconf builds up the $LIBS in reverse order
144
145 case $cf_cv_screen in
146 (pdcurses)
147         ;;
148 (*)
149         # look for curses-related libraries
150         CF_CHECK_CURSES_LIB(panel,$cf_cv_libtype,new_panel)
151         CF_CHECK_CURSES_LIB(menu,$cf_cv_libtype,menu_driver)
152         CF_CHECK_CURSES_LIB(form,$cf_cv_libtype,form_driver)
153
154         # look for curses-related headers
155         AC_CHECK_HEADERS( \
156                 nc_alloc.h \
157                 nomacros.h \
158                 form.h \
159                 menu.h \
160                 panel.h \
161                 term_entry.h \
162                 )
163         ;;
164 esac
165
166 AC_STDC_HEADERS
167 AC_HEADER_TIME
168 AC_CHECK_HEADERS( \
169 getopt.h \
170 locale.h \
171 math.h \
172 stdarg.h \
173 sys/ioctl.h \
174 sys/select.h \
175 sys/time.h \
176 termios.h \
177 unistd.h \
178 )
179
180 CF_GETOPT_HEADER
181
182 AC_CHECK_FUNCS( \
183 getopt \
184 gettimeofday \
185 )
186
187 if test "x$ac_cv_func_getopt" = xno; then
188         AC_MSG_ERROR(getopt is required for building programs)
189 fi
190
191 if test "$cf_enable_widec" = yes; then
192 AC_CHECK_FUNCS( \
193 mblen \
194 mbrlen \
195 mbrtowc \
196 mbsrtowcs \
197 mbstowcs \
198 mbtowc \
199 wcsrtombs \
200 wcstombs \
201 )
202 fi
203
204 CF_CURSES_FUNCS( \
205 assume_default_colors \
206 chgat \
207 color_set \
208 filter \
209 getbegx \
210 getcurx \
211 getmaxx \
212 getnstr \
213 getparx \
214 getwin \
215 mvvline \
216 mvwvline \
217 napms \
218 putwin \
219 resize_term \
220 resizeterm \
221 restartterm \
222 ripoffline \
223 scr_dump \
224 setupterm \
225 slk_color \
226 slk_init \
227 termattrs \
228 tgetent \
229 tigetnum \
230 tigetstr \
231 typeahead \
232 use_default_colors \
233 use_env \
234 use_extended_names \
235 use_screen \
236 use_window \
237 vid_puts \
238 vidputs \
239 vsscanf \
240 vw_printw \
241 wchgat \
242 winsstr \
243 wresize \
244 wsyncdown \
245 )
246
247 CF_TPUTS_PROTO
248 CF_NCURSES_EXT_FUNCS
249
250 if test "$cf_enable_widec" = yes
251 then
252         # workaround for systems with ncurses before 20111029, due to change of
253         # feature test macro from _XPG5 to _XOPEN_SOURCE
254         if test -n "$cf_cv_ncurses_version" && test "x$cf_cv_ncurses_version" != xno
255         then
256                 cf_define_xpg5=no
257                 AC_MSG_CHECKING(if _XPG5 should be defined to enable wide-characters)
258
259                 AC_TRY_COMPILE([
260 #include <${cf_cv_ncurses_header:-curses.h}>],
261                         [int x = _XPG5],,
262                         [cf_save_cppflags="$CPPFLAGS"
263                          CPPFLAGS="$CPPFLAGS -D_XPG5"
264                          AC_TRY_COMPILE([
265 #include <${cf_cv_ncurses_header:-curses.h}>],
266                                 [int x = _XPG5],
267                                 [cf_define_xpg5=yes])
268                          CPPFLAGS="$cf_save_cppflags"])
269                 AC_MSG_RESULT($cf_define_xpg5)
270
271                 if test "$cf_define_xpg5" = yes
272                 then
273                         CPPFLAGS="$CPPFLAGS -D_XPG5"
274                 fi
275         fi
276
277         AC_CACHE_CHECK(for wide-character functions,cf_cv_widechar_funcs,[
278         AC_TRY_LINK([
279 #include <${cf_cv_ncurses_header:-curses.h}>],
280         [
281                 static wchar_t src_wchar[2];
282                 static cchar_t dst_cchar;
283                 setcchar(&dst_cchar, src_wchar, A_NORMAL, 0, (void *) 0);
284                 ],
285                 [cf_cv_widechar_funcs=yes],
286                 [cf_cv_widechar_funcs=no])
287         ])
288         if test "$cf_cv_widechar_funcs" != no ; then
289                 AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to enable wide-character support in (n)curses])
290         else
291                 AC_DEFINE(USE_WIDEC_SUPPORT,0)
292         fi
293 else
294         AC_DEFINE(USE_WIDEC_SUPPORT,0)
295 fi
296
297 AC_CACHE_CHECK(if $cf_cv_screen library uses pthreads,cf_cv_use_pthreads,[
298 AC_TRY_LINK([
299 #include <${cf_cv_ncurses_header:-curses.h}>
300 extern void _nc_init_pthreads(void);
301 ],
302 [
303         initscr();
304         _nc_init_pthreads();
305         ],
306         [cf_cv_use_pthreads=yes],
307         [cf_cv_use_pthreads=no])
308 ])
309 test $cf_cv_use_pthreads = yes && AC_DEFINE(USE_PTHREADS)
310
311 CF_SYS_TIME_SELECT
312
313 # special check for test/ditto.c
314 CF_FUNC_OPENPTY
315 if test "$cf_cv_func_openpty" != no ; then
316         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
317         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
318         if test "x$cf_cv_lib_util" = xyes ; then
319                 CF_ADD_LIB(util,TEST_LIBS)
320         fi
321 fi
322
323 CF_FUNC_CURSES_VERSION
324
325 CF_CURSES_ACS_MAP
326 if test "$cf_enable_widec" = yes; then
327         CF_CURSES_WACS_MAP
328         CF_CURSES_WACS_SYMBOLS
329 fi
330
331 CF_CURSES_CHECK_TYPE(attr_t,long)
332
333 if test "$cf_enable_widec" = yes; then
334         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T, NCURSES_OK_MBSTATE_T)
335         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
336         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
337
338         if test "$NCURSES_OK_MBSTATE_T" = 0 ; then
339                 CF_CURSES_CHECK_TYPE(mbstate_t,long)
340         fi
341
342         if test "$NCURSES_OK_WCHAR_T" = 0 ; then
343                 CF_CURSES_CHECK_TYPE(wchar_t,long)
344         fi
345
346         if test "$NCURSES_OK_WINT_T" = 0 ; then
347                 CF_CURSES_CHECK_TYPE(wint_t,long)
348         fi
349 fi
350
351 CF_CURSES_CHECK_DATA(ospeed)
352 CF_CURSES_CHECK_DATA(boolnames)
353 CF_CURSES_CHECK_DATA(boolfnames)
354 CF_CURSES_CHECK_DATA(ttytype)
355
356 dnl ---------------------------------------------------------------------------
357 CF_HELP_MESSAGE(Testing/development Options:)
358 CF_ENABLE_WARNINGS
359 CF_DISABLE_LEAKS
360 CF_DISABLE_RPATH_HACK
361
362 TEST_ARGS="$LIBS"
363 LIBS=
364
365 dnl ---------------------------------------------------------------------------
366
367 AC_OUTPUT(Makefile,[
368 CF_PRG_RULES([$srcdir/mk-test.awk INSTALL=yes ECHO_LINK="$ECHO_LD"], .)
369         cat >>Makefile <<TEST_EOF
370
371 # These rules are generated so we do not rely on suffix rules, which do not
372 # work consistently for different make-programs (the '\$(MODEL)/' confuses
373 # some, and the '\$x' confuses others).
374 TEST_EOF
375
376 LIST=`sed -e 's/[[      ]].*//' -e '/^[[#@]]/d' $srcdir/modules`
377 for N in $LIST
378 do
379         cat >>Makefile <<TEST_EOF
380
381 \$(MODEL)/$N.o : \$(srcdir)/$N.c \\
382         \$(srcdir)/test.priv.h \\
383         ncurses_cfg.h
384         $SHOW_CC
385         $ECHO_CC\$(CC) -c \$(CFLAGS_DEFAULT) \$(srcdir)/$N.c
386 TEST_EOF
387 done
388
389 if test -f ../config.guess && test -f ../config.sub
390 then
391         cat >>Makefile <<TEST_EOF
392
393 # if we used CF_INHERIT for getting these files, we can remove them
394 distclean::
395         rm -f config.guess config.sub
396 TEST_EOF
397 fi
398 ],[
399 AWK="$AWK"
400 ECHO_CC="$ECHO_CC"
401 ECHO_LD="$ECHO_LD"
402 SHOW_CC="$SHOW_LD"
403 ],cat)