test/configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2013,2014 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1996, etc.
  30 dnl
  31 dnl $Id: configure.in,v 1.116 2014/09/05 08:43:30 tom Exp $
  32 dnl This is a simple configuration-script for the ncurses test programs that
  33 dnl allows the test-directory to be separately configured against a reference
  34 dnl system (i.e., sysvr4 curses)
  35 dnl
  36 dnl If you're configuring ncurses, you shouldn't need to use this script.
  37 dnl It's only for testing purposes.
  38 dnl
  39 dnl See http://invisible-island.net/autoconf/ for additional information.
  40 dnl ---------------------------------------------------------------------------
  41 AC_PREREQ(2.52.20030208)
  42 AC_INIT(ncurses.c)
  43 AC_CONFIG_HEADER(ncurses_cfg.h:ncurses_tst.hin)
  44
  45 CF_INHERIT_SCRIPT(config.guess)
  46 CF_INHERIT_SCRIPT(config.sub)
  47 CF_CHECK_CACHE
  48
  49 AC_ARG_PROGRAM
  50
  51 AC_PROG_MAKE_SET
  52 CF_PROG_CC
  53 AC_PROG_CPP
  54 AC_PROG_AWK
  55 CF_PROG_INSTALL
  56 CF_PROG_LINT
  57 CF_MAKE_TAGS
  58
  59 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
  60 AC_SUBST(MATH_LIB)
  61
  62 dnl Things that we don't need (or must override) if we're not building ncurses
  63 CF_TOP_BUILDDIR
  64 CC_G_OPT="-g"                                   AC_SUBST(CC_G_OPT)
  65 CC_SHARED_OPTS=unknown                  AC_SUBST(CC_SHARED_OPTS)
  66 CPPFLAGS="$CPPFLAGS"                    AC_SUBST(CPPFLAGS)
  67 DFT_DEP_SUFFIX=""                               AC_SUBST(DFT_DEP_SUFFIX)
  68 DFT_OBJ_SUBDIR=`pwd|sed -e's:.*/::'`    AC_SUBST(DFT_OBJ_SUBDIR)
  69 DFT_UPR_MODEL="NORMAL"                  AC_SUBST(DFT_UPR_MODEL)
  70 LD="ld"                                                 AC_SUBST(LD)
  71 LDFLAGS_SHARED=""                               AC_SUBST(LDFLAGS_SHARED)
  72 LDFLAGS_STATIC=""                               AC_SUBST(LDFLAGS_STATIC)
  73 LD_MODEL=""                                             AC_SUBST(LD_MODEL)
  74 LD_SHARED_OPTS=""                               AC_SUBST(LD_SHARED_OPTS)
  75 LIBTOOL=""                                              AC_SUBST(LIBTOOL)
  76 LIB_CLEAN=""                                    AC_SUBST(LIB_CLEAN)
  77 LIB_COMPILE=""                                  AC_SUBST(LIB_COMPILE)
  78 LIB_LINK='${CC}'                                AC_SUBST(LIB_LINK)
  79 LINK_TESTS=""                                   AC_SUBST(LINK_TESTS)
  80 LOCAL_LDFLAGS=""                                AC_SUBST(LOCAL_LDFLAGS)
  81 PTHREAD="-lm"                                   AC_SUBST(PTHREAD)
  82 TEST_ARGS=""                                    AC_SUBST(TEST_ARGS)
  83 TEST_DEPS=""                                    AC_SUBST(TEST_DEPS)
  84 TEST_LIBS=""                                    AC_SUBST(TEST_LIBS)
  85 TINFO_LDFLAGS=''                                AC_SUBST(TINFO_LDFLAGS)
  86 TINFO_LIBS='$(LIBS_CURSES)'             AC_SUBST(TINFO_LIBS)
  87 cf_cv_abi_version=""                    AC_SUBST(cf_cv_abi_version)
  88 cf_cv_rel_version=""                    AC_SUBST(cf_cv_rel_version)
  89 includesubdir=""                                AC_SUBST(includesubdir)
  90
  91 cf_cv_screen=curses
  92 cf_cv_libtype=
  93
  94 AC_EXEEXT
  95 AC_OBJEXT
  96
  97 CF_GCC_ATTRIBUTES
  98 CF_XOPEN_SOURCE
  99 CF_SIG_ATOMIC_T
 100
 101 dnl ---------------------------------------------------------------------------
 102 CF_HELP_MESSAGE(General Options:)
 103 CF_PKG_CONFIG
 104 CF_DISABLE_ECHO
 105
 106 dnl ---------------------------------------------------------------------------
 107 CF_HELP_MESSAGE(Curses Version-dependent Options:)
 108 CF_NCURSES_WRAP_PREFIX
 109
 110 AC_MSG_CHECKING(if you want to check for wide-character functions)
 111 CF_ARG_DISABLE(widec,
 112         [  --disable-widec         disable checks for wide-character functions],
 113         cf_enable_widec=no,
 114         cf_enable_widec=yes,
 115         yes)
 116 AC_MSG_RESULT($cf_enable_widec)
 117
 118 dnl ---------------------------------------------------------------------------
 119 CF_HELP_MESSAGE(Curses Version-dependent Options:)
 120 CF_WITH_NCURSES_ETC
 121
 122 case $cf_cv_screen in
 123 curses|curses_*)
 124         CF_NETBSD_FORM_H
 125         CF_NETBSD_MENU_H
 126         ;;
 127 ncursesw)
 128         cf_cv_libtype=w
 129         ;;
 130 esac
 131
 132 dnl If we've not specified a library, assume we're using sysvr4 libraries
 133 dnl installed conventionally (e.g., SunOS 5.x - solaris).
 134
 135 dnl Autoconf builds up the $LIBS in reverse order
 136
 137 case $cf_cv_screen in #(vi
 138 pdcurses) #(vi
 139         ;;
 140 *)
 141         # look for curses-related libraries
 142         : ${cf_panel_lib:=panel}
 143         : ${cf_menu_lib:=menu}
 144         : ${cf_form_lib:=form}
 145         AC_CHECK_LIB($cf_panel_lib$cf_cv_libtype,new_panel)
 146         AC_CHECK_LIB($cf_menu_lib$cf_cv_libtype,menu_driver)
 147         AC_CHECK_LIB($cf_form_lib$cf_cv_libtype,form_driver)
 148
 149         # look for curses-related headers
 150         AC_CHECK_HEADERS( \
 151                 nc_alloc.h \
 152                 nomacros.h \
 153                 form.h \
 154                 menu.h \
 155                 panel.h \
 156                 term_entry.h \
 157                 )
 158         ;;
 159 esac
 160
 161 AC_STDC_HEADERS
 162 AC_HEADER_TIME
 163 AC_CHECK_HEADERS( \
 164 getopt.h \
 165 locale.h \
 166 math.h \
 167 stdarg.h \
 168 sys/ioctl.h \
 169 sys/select.h \
 170 sys/time.h \
 171 termios.h \
 172 unistd.h \
 173 )
 174
 175 CF_GETOPT_HEADER
 176
 177 AC_CHECK_FUNCS( \
 178 gettimeofday \
 179 )
 180
 181 if test "$cf_enable_widec" = yes; then
 182 AC_CHECK_FUNCS( \
 183 mblen \
 184 mbrlen \
 185 mbrtowc \
 186 mbsrtowcs \
 187 mbstowcs \
 188 mbtowc \
 189 wcsrtombs \
 190 wcstombs \
 191 )
 192 fi
 193
 194 CF_CURSES_FUNCS( \
 195 assume_default_colors \
 196 chgat \
 197 color_set \
 198 filter \
 199 getbegx \
 200 getcurx \
 201 getmaxx \
 202 getnstr \
 203 getparx \
 204 getwin \
 205 mvvline \
 206 mvwvline \
 207 napms \
 208 putwin \
 209 resize_term \
 210 resizeterm \
 211 ripoffline \
 212 scr_dump \
 213 setupterm \
 214 slk_color \
 215 slk_init \
 216 termattrs \
 217 tgetent \
 218 tigetnum \
 219 tigetstr \
 220 typeahead \
 221 use_default_colors \
 222 use_env \
 223 use_extended_names \
 224 use_screen \
 225 use_window \
 226 vid_puts \
 227 vidputs \
 228 vsscanf \
 229 vw_printw \
 230 wchgat \
 231 winsstr \
 232 wresize \
 233 wsyncdown \
 234 )
 235
 236 CF_TPUTS_PROTO
 237 CF_NCURSES_EXT_FUNCS
 238
 239 if test "$cf_enable_widec" = yes
 240 then
 241         # workaround for systems with ncurses before 20111029, due to change of
 242         # feature test macro from _XPG5 to _XOPEN_SOURCE
 243         if test -n "$cf_cv_ncurses_version" && test "x$cf_cv_ncurses_version" != xno
 244         then
 245                 cf_define_xpg5=no
 246                 AC_MSG_CHECKING(if _XPG5 should be defined to enable wide-characters)
 247
 248                 AC_TRY_COMPILE([
 249 #include <${cf_cv_ncurses_header:-curses.h}>],
 250                         [int x = _XPG5],,
 251                         [cf_save_cppflags="$CPPFLAGS"
 252                          CPPFLAGS="$CPPFLAGS -D_XPG5"
 253                          AC_TRY_COMPILE([
 254 #include <${cf_cv_ncurses_header:-curses.h}>],
 255                                 [int x = _XPG5],
 256                                 [cf_define_xpg5=yes])
 257                          CPPFLAGS="$cf_save_cppflags"])
 258                 AC_MSG_RESULT($cf_define_xpg5)
 259
 260                 if test "$cf_define_xpg5" = yes
 261                 then
 262                         CPPFLAGS="$CPPFLAGS -D_XPG5"
 263                 fi
 264         fi
 265
 266         AC_CACHE_CHECK(for wide-character functions,cf_cv_widechar_funcs,[
 267         AC_TRY_LINK([
 268 #include <${cf_cv_ncurses_header:-curses.h}>],
 269         [
 270                 static wchar_t src_wchar[2];
 271                 static cchar_t dst_cchar;
 272                 setcchar(&dst_cchar, src_wchar, A_NORMAL, 0, (void *) 0);
 273                 ],
 274                 [cf_cv_widechar_funcs=yes],
 275                 [cf_cv_widechar_funcs=no])
 276         ])
 277         if test "$cf_cv_widechar_funcs" != no ; then
 278                 AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to enable wide-character support in (n)curses])
 279         else
 280                 AC_DEFINE(USE_WIDEC_SUPPORT,0)
 281         fi
 282 else
 283         AC_DEFINE(USE_WIDEC_SUPPORT,0)
 284 fi
 285
 286 CF_SYS_TIME_SELECT
 287 CF_FUNC_CURSES_VERSION
 288
 289 CF_CURSES_ACS_MAP
 290 if test "$cf_enable_widec" = yes; then
 291         CF_CURSES_WACS_MAP
 292         CF_CURSES_WACS_SYMBOLS
 293 fi
 294
 295 CF_CURSES_CHECK_TYPE(attr_t,long)
 296
 297 if test "$cf_enable_widec" = yes; then
 298         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T, NCURSES_OK_MBSTATE_T)
 299         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 300         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 301
 302         if test "$NCURSES_OK_MBSTATE_T" = 0 ; then
 303                 CF_CURSES_CHECK_TYPE(mbstate_t,long)
 304         fi
 305
 306         if test "$NCURSES_OK_WCHAR_T" = 0 ; then
 307                 CF_CURSES_CHECK_TYPE(wchar_t,long)
 308         fi
 309
 310         if test "$NCURSES_OK_WINT_T" = 0 ; then
 311                 CF_CURSES_CHECK_TYPE(wint_t,long)
 312         fi
 313 fi
 314
 315 CF_CURSES_CHECK_DATA(boolnames)
 316 CF_CURSES_CHECK_DATA(boolfnames)
 317
 318 dnl ---------------------------------------------------------------------------
 319 CF_HELP_MESSAGE(Testing/development Options:)
 320 CF_ENABLE_WARNINGS
 321 CF_DISABLE_LEAKS
 322 CF_DISABLE_RPATH_HACK
 323
 324 TEST_ARGS="$LIBS"
 325 LIBS=
 326
 327 dnl ---------------------------------------------------------------------------
 328
 329 AC_OUTPUT(Makefile,[
 330 CF_PRG_RULES([$srcdir/mk-test.awk INSTALL=yes ECHO_LINK="$ECHO_LD"], .)
 331         cat >>Makefile <<TEST_EOF
 332
 333 # These rules are generated so we do not rely on suffix rules, which do not
 334 # work consistently for different make-programs (the '\$(MODEL)/' confuses
 335 # some, and the '\$x' confuses others).
 336 TEST_EOF
 337
 338 LIST=`sed -e 's/[[      ]].*//' -e '/^[[#@]]/d' $srcdir/modules`
 339 for N in $LIST
 340 do
 341         cat >>Makefile <<TEST_EOF
 342
 343 \$(MODEL)/$N.o : \$(srcdir)/$N.c \\
 344         \$(srcdir)/test.priv.h \\
 345         ncurses_cfg.h
 346         $SHOW_CC
 347         $ECHO_CC\$(CC) -c \$(CFLAGS_DEFAULT) \$(srcdir)/$N.c
 348 TEST_EOF
 349 done
 350
 351 if test -f ../config.guess && test -f ../config.sub
 352 then
 353         cat >>Makefile <<TEST_EOF
 354
 355 # if we used CF_INHERIT for getting these files, we can remove them
 356 distclean::
 357         rm -f config.guess config.sub
 358 TEST_EOF
 359 fi
 360 ],[
 361 AWK="$AWK"
 362 ECHO_CC="$ECHO_CC"
 363 ECHO_LD="$ECHO_LD"
 364 SHOW_CC="$SHOW_LD"
 365 ],cat)