Ada95/aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 2010-2011,2012 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.45 2012/02/18 23:21:42 tom Exp $
  32 dnl Macros used in NCURSES Ada95 auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl CF_ACVERSION_CHECK version: 2 updated: 2011/05/08 11:22:03
  43 dnl ------------------
  44 dnl Conditionally generate script according to whether we're using a given autoconf.
  45 dnl
  46 dnl $1 = version to compare against
  47 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  48 dnl $3 = code to use if AC_ACVERSION is older than $1.
  49 define(CF_ACVERSION_CHECK,
  50 [
  51 ifdef([m4_version_compare],
  52 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  53 [CF_ACVERSION_COMPARE(
  54 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  55 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  56 dnl ---------------------------------------------------------------------------
  57 dnl CF_ACVERSION_COMPARE version: 2 updated: 2011/04/14 20:56:50
  58 dnl --------------------
  59 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  60 dnl                      MAJOR2, MINOR2, TERNARY2,
  61 dnl                      PRINTABLE2, not FOUND, FOUND)
  62 define(CF_ACVERSION_COMPARE,
  63 [ifelse(builtin([eval], [$2 < $5]), 1,
  64 [ifelse([$8], , ,[$8])],
  65 [ifelse([$9], , ,[$9])])])dnl
  66 dnl ---------------------------------------------------------------------------
  67 dnl CF_ADA_INCLUDE_DIRS version: 6 updated: 2010/02/26 19:52:07
  68 dnl -------------------
  69 dnl Construct the list of include-options for the C programs in the Ada95
  70 dnl binding.
  71 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  72 [
  73 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  74 if test "$srcdir" != "."; then
  75         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  76 fi
  77 if test "$GCC" != yes; then
  78         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  79 elif test "$includedir" != "/usr/include"; then
  80         if test "$includedir" = '${prefix}/include' ; then
  81                 if test $prefix != /usr ; then
  82                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  83                 fi
  84         else
  85                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  86         fi
  87 fi
  88 AC_SUBST(ACPPFLAGS)
  89 ])dnl
  90 dnl ---------------------------------------------------------------------------
  91 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
  92 dnl ---------------
  93 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
  94 AC_DEFUN([CF_ADD_ADAFLAGS],[
  95         ADAFLAGS="$ADAFLAGS $1"
  96         AC_SUBST(ADAFLAGS)
  97 ])dnl
  98 dnl ---------------------------------------------------------------------------
  99 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
 100 dnl -------------
 101 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 102 dnl The second parameter if given makes this macro verbose.
 103 dnl
 104 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 105 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 106 dnl confused by the quotes (which require backslashes to keep them usable).
 107 AC_DEFUN([CF_ADD_CFLAGS],
 108 [
 109 cf_fix_cppflags=no
 110 cf_new_cflags=
 111 cf_new_cppflags=
 112 cf_new_extra_cppflags=
 113
 114 for cf_add_cflags in $1
 115 do
 116 case $cf_fix_cppflags in
 117 no)
 118         case $cf_add_cflags in #(vi
 119         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
 120                 case $cf_add_cflags in
 121                 -D*)
 122                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 123
 124                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 125                                 && test -z "${cf_tst_cflags}" \
 126                                 && cf_fix_cppflags=yes
 127
 128                         if test $cf_fix_cppflags = yes ; then
 129                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 130                                 continue
 131                         elif test "${cf_tst_cflags}" = "\"'" ; then
 132                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 133                                 continue
 134                         fi
 135                         ;;
 136                 esac
 137                 case "$CPPFLAGS" in
 138                 *$cf_add_cflags) #(vi
 139                         ;;
 140                 *) #(vi
 141                         case $cf_add_cflags in #(vi
 142                         -D*)
 143                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 144                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 145                                 ;;
 146                         esac
 147                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 148                         ;;
 149                 esac
 150                 ;;
 151         *)
 152                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 153                 ;;
 154         esac
 155         ;;
 156 yes)
 157         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 158
 159         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 160
 161         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 162                 && test -z "${cf_tst_cflags}" \
 163                 && cf_fix_cppflags=no
 164         ;;
 165 esac
 166 done
 167
 168 if test -n "$cf_new_cflags" ; then
 169         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 170         CFLAGS="$CFLAGS $cf_new_cflags"
 171 fi
 172
 173 if test -n "$cf_new_cppflags" ; then
 174         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 175         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 176 fi
 177
 178 if test -n "$cf_new_extra_cppflags" ; then
 179         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 180         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 181 fi
 182
 183 AC_SUBST(EXTRA_CPPFLAGS)
 184
 185 ])dnl
 186 dnl ---------------------------------------------------------------------------
 187 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 188 dnl -------------
 189 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 190 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 191 dnl but old versions (and some misinstalled ones) need that.  To make things
 192 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 193 dnl the include-path).
 194 AC_DEFUN([CF_ADD_INCDIR],
 195 [
 196 if test -n "$1" ; then
 197   for cf_add_incdir in $1
 198   do
 199         while test $cf_add_incdir != /usr/include
 200         do
 201           if test -d $cf_add_incdir
 202           then
 203                 cf_have_incdir=no
 204                 if test -n "$CFLAGS$CPPFLAGS" ; then
 205                   # a loop is needed to ensure we can add subdirs of existing dirs
 206                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 207                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 208                           cf_have_incdir=yes; break
 209                         fi
 210                   done
 211                 fi
 212
 213                 if test "$cf_have_incdir" = no ; then
 214                   if test "$cf_add_incdir" = /usr/local/include ; then
 215                         if test "$GCC" = yes
 216                         then
 217                           cf_save_CPPFLAGS=$CPPFLAGS
 218                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 219                           AC_TRY_COMPILE([#include <stdio.h>],
 220                                   [printf("Hello")],
 221                                   [],
 222                                   [cf_have_incdir=yes])
 223                           CPPFLAGS=$cf_save_CPPFLAGS
 224                         fi
 225                   fi
 226                 fi
 227
 228                 if test "$cf_have_incdir" = no ; then
 229                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 230                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 231
 232                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 233                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 234                   cf_add_incdir="$cf_top_incdir"
 235                 else
 236                   break
 237                 fi
 238           fi
 239         done
 240   done
 241 fi
 242 ])dnl
 243 dnl ---------------------------------------------------------------------------
 244 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 245 dnl ----------
 246 dnl Add a library, used to enforce consistency.
 247 dnl
 248 dnl $1 = library to add, without the "-l"
 249 dnl $2 = variable to update (default $LIBS)
 250 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 251 dnl ---------------------------------------------------------------------------
 252 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 253 dnl -------------
 254 dnl     Adds to the library-path
 255 dnl
 256 dnl     Some machines have trouble with multiple -L options.
 257 dnl
 258 dnl $1 is the (list of) directory(s) to add
 259 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 260 dnl
 261 AC_DEFUN([CF_ADD_LIBDIR],
 262 [
 263 if test -n "$1" ; then
 264   for cf_add_libdir in $1
 265   do
 266     if test $cf_add_libdir = /usr/lib ; then
 267       :
 268     elif test -d $cf_add_libdir
 269     then
 270       cf_have_libdir=no
 271       if test -n "$LDFLAGS$LIBS" ; then
 272         # a loop is needed to ensure we can add subdirs of existing dirs
 273         for cf_test_libdir in $LDFLAGS $LIBS ; do
 274           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 275             cf_have_libdir=yes; break
 276           fi
 277         done
 278       fi
 279       if test "$cf_have_libdir" = no ; then
 280         CF_VERBOSE(adding $cf_add_libdir to library-path)
 281         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 282       fi
 283     fi
 284   done
 285 fi
 286 ])dnl
 287 dnl ---------------------------------------------------------------------------
 288 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 289 dnl -----------
 290 dnl Add one or more libraries, used to enforce consistency.
 291 dnl
 292 dnl $1 = libraries to add, with the "-l", etc.
 293 dnl $2 = variable to update (default $LIBS)
 294 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 295 dnl ---------------------------------------------------------------------------
 296 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
 297 dnl ------------------
 298 dnl Append to a search-list for a nonstandard header/lib-file
 299 dnl     $1 = the variable to return as result
 300 dnl     $2 = the package name
 301 dnl     $3 = the subdirectory, e.g., bin, include or lib
 302 dnl $4 = the directory under which we will test for subdirectories
 303 dnl $5 = a directory that we do not want $4 to match
 304 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 305 [
 306 test "$4" != "$5" && \
 307 test -d "$4" && \
 308 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
 309         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 310         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 311         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 312         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 313         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 314         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 315 }
 316 ])dnl
 317 dnl ---------------------------------------------------------------------------
 318 dnl CF_ANSI_CC_CHECK version: 11 updated: 2011/07/01 19:47:45
 319 dnl ----------------
 320 dnl This was originally adapted from the macros 'fp_PROG_CC_STDC' and
 321 dnl 'fp_C_PROTOTYPES' in the sharutils 4.2 distribution.
 322 AC_DEFUN([CF_ANSI_CC_CHECK],
 323 [
 324 # This should have been defined by AC_PROG_CC
 325 : ${CC:=cc}
 326
 327 # Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 328 # into CC.  This will not help with broken scripts that wrap the compiler with
 329 # options, but eliminates a more common category of user confusion.
 330 AC_MSG_CHECKING(\$CC variable)
 331 case "$CC" in #(vi
 332 *[[\ \  ]]-[[IUD]]*)
 333         AC_MSG_RESULT(broken)
 334         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 335         # humor him...
 336         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 337         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 338         CF_ADD_CFLAGS($cf_flags)
 339         ;;
 340 *)
 341         AC_MSG_RESULT(ok)
 342         ;;
 343 esac
 344
 345 AC_CACHE_CHECK(for ${CC:-cc} option to accept ANSI C, cf_cv_ansi_cc,[
 346 cf_cv_ansi_cc=no
 347 cf_save_CFLAGS="$CFLAGS"
 348 cf_save_CPPFLAGS="$CPPFLAGS"
 349 # Don't try gcc -ansi; that turns off useful extensions and
 350 # breaks some systems' header files.
 351 # AIX                   -qlanglvl=ansi
 352 # Ultrix and OSF/1      -std1
 353 # HP-UX                 -Aa -D_HPUX_SOURCE
 354 # SVR4                  -Xc
 355 # UnixWare 1.2          (cannot use -Xc, since ANSI/POSIX clashes)
 356 for cf_arg in "-DCC_HAS_PROTOS" \
 357         "" \
 358         -qlanglvl=ansi \
 359         -std1 \
 360         -Ae \
 361         "-Aa -D_HPUX_SOURCE" \
 362         -Xc
 363 do
 364         CF_ADD_CFLAGS($cf_arg)
 365         AC_TRY_COMPILE(
 366 [
 367 #ifndef CC_HAS_PROTOS
 368 #if !defined(__STDC__) || (__STDC__ != 1)
 369 choke me
 370 #endif
 371 #endif
 372 ],[
 373         int test (int i, double x);
 374         struct s1 {int (*f) (int a);};
 375         struct s2 {int (*f) (double a);};],
 376         [cf_cv_ansi_cc="$cf_arg"; break])
 377 done
 378 CFLAGS="$cf_save_CFLAGS"
 379 CPPFLAGS="$cf_save_CPPFLAGS"
 380 ])
 381
 382 if test "$cf_cv_ansi_cc" != "no"; then
 383 if test ".$cf_cv_ansi_cc" != ".-DCC_HAS_PROTOS"; then
 384         CF_ADD_CFLAGS($cf_cv_ansi_cc)
 385 else
 386         AC_DEFINE(CC_HAS_PROTOS)
 387 fi
 388 fi
 389 ])dnl
 390 dnl ---------------------------------------------------------------------------
 391 dnl CF_ANSI_CC_REQD version: 4 updated: 2008/03/23 14:48:54
 392 dnl ---------------
 393 dnl For programs that must use an ANSI compiler, obtain compiler options that
 394 dnl will make it recognize prototypes.  We'll do preprocessor checks in other
 395 dnl macros, since tools such as unproto can fake prototypes, but only part of
 396 dnl the preprocessor.
 397 AC_DEFUN([CF_ANSI_CC_REQD],
 398 [AC_REQUIRE([CF_ANSI_CC_CHECK])
 399 if test "$cf_cv_ansi_cc" = "no"; then
 400         AC_MSG_ERROR(
 401 [Your compiler does not appear to recognize prototypes.
 402 You have the following choices:
 403         a. adjust your compiler options
 404         b. get an up-to-date compiler
 405         c. use a wrapper such as unproto])
 406 fi
 407 ])dnl
 408 dnl ---------------------------------------------------------------------------
 409 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 410 dnl -----------
 411 dnl Check for suitable "ar" (archiver) options for updating an archive.
 412 AC_DEFUN([CF_AR_FLAGS],[
 413 AC_REQUIRE([CF_PROG_AR])
 414
 415 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 416         cf_cv_ar_flags=unknown
 417         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 418         do
 419
 420                 # check if $ARFLAGS already contains this choice
 421                 if test "x$ARFLAGS" != "x" ; then
 422                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 423                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 424                                 cf_cv_ar_flags=
 425                                 break
 426                         fi
 427                 fi
 428
 429                 rm -f conftest.$ac_cv_objext
 430                 rm -f conftest.a
 431
 432                 cat >conftest.$ac_ext <<EOF
 433 #line __oline__ "configure"
 434 int     testdata[[3]] = { 123, 456, 789 };
 435 EOF
 436                 if AC_TRY_EVAL(ac_compile) ; then
 437                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 438                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 439                         if test -f conftest.a ; then
 440                                 cf_cv_ar_flags=$cf_ar_flags
 441                                 break
 442                         fi
 443                 else
 444                         CF_VERBOSE(cannot compile test-program)
 445                         break
 446                 fi
 447         done
 448         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 449 ])
 450
 451 if test -n "$ARFLAGS" ; then
 452         if test -n "$cf_cv_ar_flags" ; then
 453                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 454         fi
 455 else
 456         ARFLAGS=$cf_cv_ar_flags
 457 fi
 458
 459 AC_SUBST(ARFLAGS)
 460 ])
 461 dnl ---------------------------------------------------------------------------
 462 dnl CF_BUILD_CC version: 6 updated: 2006/10/14 15:23:15
 463 dnl -----------
 464 dnl If we're cross-compiling, allow the user to override the tools and their
 465 dnl options.  The configure script is oriented toward identifying the host
 466 dnl compiler, etc., but we need a build compiler to generate parts of the
 467 dnl source.
 468 dnl
 469 dnl $1 = default for $CPPFLAGS
 470 dnl $2 = default for $LIBS
 471 AC_DEFUN([CF_BUILD_CC],[
 472 AC_REQUIRE([CF_PROG_EXT])
 473 if test "$cross_compiling" = yes ; then
 474
 475         # defaults that we might want to override
 476         : ${BUILD_CFLAGS:=''}
 477         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 478         : ${BUILD_LDFLAGS:=''}
 479         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 480         : ${BUILD_EXEEXT:='$x'}
 481         : ${BUILD_OBJEXT:='o'}
 482
 483         AC_ARG_WITH(build-cc,
 484                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 485                 [BUILD_CC="$withval"],
 486                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 487         AC_MSG_CHECKING(for native build C compiler)
 488         AC_MSG_RESULT($BUILD_CC)
 489
 490         AC_MSG_CHECKING(for native build C preprocessor)
 491         AC_ARG_WITH(build-cpp,
 492                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 493                 [BUILD_CPP="$withval"],
 494                 [BUILD_CPP='${BUILD_CC} -E'])
 495         AC_MSG_RESULT($BUILD_CPP)
 496
 497         AC_MSG_CHECKING(for native build C flags)
 498         AC_ARG_WITH(build-cflags,
 499                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 500                 [BUILD_CFLAGS="$withval"])
 501         AC_MSG_RESULT($BUILD_CFLAGS)
 502
 503         AC_MSG_CHECKING(for native build C preprocessor-flags)
 504         AC_ARG_WITH(build-cppflags,
 505                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 506                 [BUILD_CPPFLAGS="$withval"])
 507         AC_MSG_RESULT($BUILD_CPPFLAGS)
 508
 509         AC_MSG_CHECKING(for native build linker-flags)
 510         AC_ARG_WITH(build-ldflags,
 511                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 512                 [BUILD_LDFLAGS="$withval"])
 513         AC_MSG_RESULT($BUILD_LDFLAGS)
 514
 515         AC_MSG_CHECKING(for native build linker-libraries)
 516         AC_ARG_WITH(build-libs,
 517                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 518                 [BUILD_LIBS="$withval"])
 519         AC_MSG_RESULT($BUILD_LIBS)
 520
 521         # this assumes we're on Unix.
 522         BUILD_EXEEXT=
 523         BUILD_OBJEXT=o
 524
 525         : ${BUILD_CC:='${CC}'}
 526
 527         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 528                 AC_MSG_ERROR([Cross-build requires two compilers.
 529 Use --with-build-cc to specify the native compiler.])
 530         fi
 531
 532 else
 533         : ${BUILD_CC:='${CC}'}
 534         : ${BUILD_CPP:='${CPP}'}
 535         : ${BUILD_CFLAGS:='${CFLAGS}'}
 536         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 537         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 538         : ${BUILD_LIBS:='${LIBS}'}
 539         : ${BUILD_EXEEXT:='$x'}
 540         : ${BUILD_OBJEXT:='o'}
 541 fi
 542
 543 AC_SUBST(BUILD_CC)
 544 AC_SUBST(BUILD_CPP)
 545 AC_SUBST(BUILD_CFLAGS)
 546 AC_SUBST(BUILD_CPPFLAGS)
 547 AC_SUBST(BUILD_LDFLAGS)
 548 AC_SUBST(BUILD_LIBS)
 549 AC_SUBST(BUILD_EXEEXT)
 550 AC_SUBST(BUILD_OBJEXT)
 551 ])dnl
 552 dnl ---------------------------------------------------------------------------
 553 dnl CF_CFG_DEFAULTS version: 8 updated: 2011/06/04 20:09:13
 554 dnl ---------------
 555 dnl Determine the default configuration into which we'll install ncurses.  This
 556 dnl can be overridden by the user's command-line options.  There's two items to
 557 dnl look for:
 558 dnl     1. the prefix (e.g., /usr)
 559 dnl     2. the header files (e.g., /usr/include/ncurses)
 560 dnl We'll look for a previous installation of ncurses and use the same defaults.
 561 dnl
 562 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 563 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 564 dnl programs from a vendor's.
 565 AC_DEFUN([CF_CFG_DEFAULTS],
 566 [
 567 AC_MSG_CHECKING(for prefix)
 568 if test "x$prefix" = "xNONE" ; then
 569         case "$cf_cv_system_name" in
 570                 # non-vendor systems don't have a conflict
 571         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|k*bsd*-gnu)
 572                 prefix=/usr
 573                 ;;
 574         *)      prefix=$ac_default_prefix
 575                 ;;
 576         esac
 577 fi
 578 AC_MSG_RESULT($prefix)
 579
 580 if test "x$prefix" = "xNONE" ; then
 581 AC_MSG_CHECKING(for default include-directory)
 582 test -n "$verbose" && echo 1>&AC_FD_MSG
 583 for cf_symbol in \
 584         $includedir \
 585         $includedir/ncurses \
 586         $prefix/include \
 587         $prefix/include/ncurses \
 588         /usr/local/include \
 589         /usr/local/include/ncurses \
 590         /usr/include \
 591         /usr/include/ncurses
 592 do
 593         cf_dir=`eval echo $cf_symbol`
 594         if test -f $cf_dir/curses.h ; then
 595         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 596                 includedir="$cf_symbol"
 597                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 598                 break
 599         fi
 600         fi
 601         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 602 done
 603 AC_MSG_RESULT($includedir)
 604 fi
 605 ])dnl
 606 dnl ---------------------------------------------------------------------------
 607 dnl CF_CHECK_CACHE version: 11 updated: 2008/03/23 14:45:59
 608 dnl --------------
 609 dnl Check if we're accidentally using a cache from a different machine.
 610 dnl Derive the system name, as a check for reusing the autoconf cache.
 611 dnl
 612 dnl If we've packaged config.guess and config.sub, run that (since it does a
 613 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 614 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 615 dnl which is useful in cross-compiles.
 616 dnl
 617 dnl Note: we would use $ac_config_sub, but that is one of the places where
 618 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 619 AC_DEFUN([CF_CHECK_CACHE],
 620 [
 621 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 622         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 623         system_name="$host_os"
 624 else
 625         system_name="`(uname -s -r) 2>/dev/null`"
 626         if test -z "$system_name" ; then
 627                 system_name="`(hostname) 2>/dev/null`"
 628         fi
 629 fi
 630 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name")
 631 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 632
 633 test -z "$system_name" && system_name="$cf_cv_system_name"
 634 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 635
 636 if test ".$system_name" != ".$cf_cv_system_name" ; then
 637         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 638         AC_MSG_ERROR("Please remove config.cache and try again.")
 639 fi
 640 ])dnl
 641 dnl ---------------------------------------------------------------------------
 642 dnl CF_CURSES_HEADER version: 3 updated: 2011/05/01 19:47:45
 643 dnl ----------------
 644 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
 645 dnl variations of ncurses' installs.
 646 dnl
 647 dnl $1 = ncurses when looking for ncurses, or is empty
 648 AC_DEFUN([CF_CURSES_HEADER],[
 649 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
 650 cf_cv_ncurses_header=none
 651 for cf_header in ifelse($1,,,[ \
 652     $1/ncurses.h \
 653         $1/curses.h]) \
 654         ncurses.h \
 655         curses.h ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
 656 do
 657 AC_TRY_COMPILE([#include <${cf_header}>],
 658         [initscr(); tgoto("?", 0,0)],
 659         [cf_cv_ncurses_header=$cf_header; break],[])
 660 done
 661 ])
 662
 663 if test "$cf_cv_ncurses_header" = none ; then
 664         AC_MSG_ERROR(No curses header-files found)
 665 fi
 666
 667 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
 668 AC_CHECK_HEADERS($cf_cv_ncurses_header)
 669 ])dnl
 670 dnl ---------------------------------------------------------------------------
 671 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
 672 dnl ----------
 673 dnl "dirname" is not portable, so we fake it with a shell script.
 674 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
 675 dnl ---------------------------------------------------------------------------
 676 dnl CF_ENABLE_PC_FILES version: 7 updated: 2011/12/10 18:58:47
 677 dnl ------------------
 678 dnl This is the "--enable-pc-files" option, which is available if there is a
 679 dnl pkg-config configuration on the local machine.
 680 AC_DEFUN([CF_ENABLE_PC_FILES],[
 681 AC_REQUIRE([CF_PKG_CONFIG])
 682 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
 683
 684 if test "$PKG_CONFIG" != none ; then
 685         if test -n "$PKG_CONFIG_LIBDIR" && test -d "$PKG_CONFIG_LIBDIR" ; then
 686                 AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
 687                 AC_ARG_ENABLE(pc-files,
 688                         [  --enable-pc-files       generate and install .pc files for pkg-config],
 689                         [enable_pc_files=$enableval],
 690                         [enable_pc_files=no])
 691                 AC_MSG_RESULT($enable_pc_files)
 692         elif test -z "$PKG_CONFIG_LIBDIR" || test "$PKG_CONFIG_LIBDIR" != no; then
 693                 enable_pc_files=no
 694                 AC_MSG_WARN(did not find $PKG_CONFIG library)
 695         fi
 696 else
 697         enable_pc_files=no
 698 fi
 699 ])dnl
 700 dnl ---------------------------------------------------------------------------
 701 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
 702 dnl ---------------
 703 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
 704 dnl prefer a standard location, and use -L options only if we do not find the
 705 dnl library in the standard library location(s).
 706 dnl     $1 = library name
 707 dnl     $2 = library class, usually the same as library name
 708 dnl     $3 = includes
 709 dnl     $4 = code fragment to compile/link
 710 dnl     $5 = corresponding function-name
 711 dnl     $6 = flag, nonnull if failure should not cause an error-exit
 712 dnl
 713 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
 714 dnl to use a -L option.
 715 AC_DEFUN([CF_FIND_LIBRARY],
 716 [
 717         eval 'cf_cv_have_lib_'$1'=no'
 718         cf_libdir=""
 719         AC_CHECK_FUNC($5,
 720                 eval 'cf_cv_have_lib_'$1'=yes',[
 721                 cf_save_LIBS="$LIBS"
 722                 AC_MSG_CHECKING(for $5 in -l$1)
 723                 LIBS="-l$1 $LIBS"
 724                 AC_TRY_LINK([$3],[$4],
 725                         [AC_MSG_RESULT(yes)
 726                          eval 'cf_cv_have_lib_'$1'=yes'
 727                         ],
 728                         [AC_MSG_RESULT(no)
 729                         CF_LIBRARY_PATH(cf_search,$2)
 730                         for cf_libdir in $cf_search
 731                         do
 732                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
 733                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
 734                                 AC_TRY_LINK([$3],[$4],
 735                                         [AC_MSG_RESULT(yes)
 736                                          eval 'cf_cv_have_lib_'$1'=yes'
 737                                          break],
 738                                         [AC_MSG_RESULT(no)
 739                                          LIBS="$cf_save_LIBS"])
 740                         done
 741                         ])
 742                 ])
 743 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
 744 ifelse($6,,[
 745 if test $cf_found_library = no ; then
 746         AC_MSG_ERROR(Cannot link $1 library)
 747 fi
 748 ])
 749 ])dnl
 750 dnl ---------------------------------------------------------------------------
 751 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
 752 dnl ---------------
 753 dnl Find a library (specifically the linkage used in the code fragment),
 754 dnl searching for it if it is not already in the library path.
 755 dnl See also CF_ADD_SEARCHPATH.
 756 dnl
 757 dnl Parameters (4-on are optional):
 758 dnl     $1 = headers for library entrypoint
 759 dnl     $2 = code fragment for library entrypoint
 760 dnl     $3 = the library name without the "-l" option or ".so" suffix.
 761 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
 762 dnl     $5 = action to perform if not successful
 763 dnl     $6 = module name, if not the same as the library name
 764 dnl     $7 = extra libraries
 765 dnl
 766 dnl Sets these variables:
 767 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
 768 dnl     $cf_cv_header_path_$3 - include-directory if needed
 769 dnl     $cf_cv_library_path_$3 - library-directory if needed
 770 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
 771 AC_DEFUN([CF_FIND_LINKAGE],[
 772
 773 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
 774 # will be set on completion of the AC_TRY_LINK below.
 775 cf_cv_header_path_$3=
 776 cf_cv_library_path_$3=
 777
 778 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
 779
 780 cf_save_LIBS="$LIBS"
 781
 782 AC_TRY_LINK([$1],[$2],[
 783         cf_cv_find_linkage_$3=yes
 784         cf_cv_header_path_$3=/usr/include
 785         cf_cv_library_path_$3=/usr/lib
 786 ],[
 787
 788 LIBS="-l$3 $7 $cf_save_LIBS"
 789
 790 AC_TRY_LINK([$1],[$2],[
 791         cf_cv_find_linkage_$3=yes
 792         cf_cv_header_path_$3=/usr/include
 793         cf_cv_library_path_$3=/usr/lib
 794         cf_cv_library_file_$3="-l$3"
 795 ],[
 796         cf_cv_find_linkage_$3=no
 797         LIBS="$cf_save_LIBS"
 798
 799     CF_VERBOSE(find linkage for $3 library)
 800     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
 801
 802     cf_save_CPPFLAGS="$CPPFLAGS"
 803     cf_test_CPPFLAGS="$CPPFLAGS"
 804
 805     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
 806     for cf_cv_header_path_$3 in $cf_search
 807     do
 808       if test -d $cf_cv_header_path_$3 ; then
 809         CF_VERBOSE(... testing $cf_cv_header_path_$3)
 810         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
 811         AC_TRY_COMPILE([$1],[$2],[
 812             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
 813             cf_cv_find_linkage_$3=maybe
 814             cf_test_CPPFLAGS="$CPPFLAGS"
 815             break],[
 816             CPPFLAGS="$cf_save_CPPFLAGS"
 817             ])
 818       fi
 819     done
 820
 821     if test "$cf_cv_find_linkage_$3" = maybe ; then
 822
 823       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
 824
 825       cf_save_LIBS="$LIBS"
 826       cf_save_LDFLAGS="$LDFLAGS"
 827
 828       ifelse([$6],,,[
 829         CPPFLAGS="$cf_test_CPPFLAGS"
 830         LIBS="-l$3 $7 $cf_save_LIBS"
 831         AC_TRY_LINK([$1],[$2],[
 832             CF_VERBOSE(... found $3 library in system)
 833             cf_cv_find_linkage_$3=yes])
 834             CPPFLAGS="$cf_save_CPPFLAGS"
 835             LIBS="$cf_save_LIBS"
 836             ])
 837
 838       if test "$cf_cv_find_linkage_$3" != yes ; then
 839         CF_LIBRARY_PATH(cf_search,$3)
 840         for cf_cv_library_path_$3 in $cf_search
 841         do
 842           if test -d $cf_cv_library_path_$3 ; then
 843             CF_VERBOSE(... testing $cf_cv_library_path_$3)
 844             CPPFLAGS="$cf_test_CPPFLAGS"
 845             LIBS="-l$3 $7 $cf_save_LIBS"
 846             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
 847             AC_TRY_LINK([$1],[$2],[
 848                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
 849                 cf_cv_find_linkage_$3=yes
 850                 cf_cv_library_file_$3="-l$3"
 851                 break],[
 852                 CPPFLAGS="$cf_save_CPPFLAGS"
 853                 LIBS="$cf_save_LIBS"
 854                 LDFLAGS="$cf_save_LDFLAGS"
 855                 ])
 856           fi
 857         done
 858         CPPFLAGS="$cf_save_CPPFLAGS"
 859         LDFLAGS="$cf_save_LDFLAGS"
 860       fi
 861
 862     else
 863       cf_cv_find_linkage_$3=no
 864     fi
 865     ],$7)
 866 ])
 867
 868 LIBS="$cf_save_LIBS"
 869
 870 if test "$cf_cv_find_linkage_$3" = yes ; then
 871 ifelse([$4],,[
 872         CF_ADD_INCDIR($cf_cv_header_path_$3)
 873         CF_ADD_LIBDIR($cf_cv_library_path_$3)
 874         CF_ADD_LIB($3)
 875 ],[$4])
 876 else
 877 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
 878 fi
 879 ])dnl
 880 dnl ---------------------------------------------------------------------------
 881 dnl CF_GCC_ATTRIBUTES version: 14 updated: 2010/10/23 15:52:32
 882 dnl -----------------
 883 dnl Test for availability of useful gcc __attribute__ directives to quiet
 884 dnl compiler warnings.  Though useful, not all are supported -- and contrary
 885 dnl to documentation, unrecognized directives cause older compilers to barf.
 886 AC_DEFUN([CF_GCC_ATTRIBUTES],
 887 [
 888 if test "$GCC" = yes
 889 then
 890 cat > conftest.i <<EOF
 891 #ifndef GCC_PRINTF
 892 #define GCC_PRINTF 0
 893 #endif
 894 #ifndef GCC_SCANF
 895 #define GCC_SCANF 0
 896 #endif
 897 #ifndef GCC_NORETURN
 898 #define GCC_NORETURN /* nothing */
 899 #endif
 900 #ifndef GCC_UNUSED
 901 #define GCC_UNUSED /* nothing */
 902 #endif
 903 EOF
 904 if test "$GCC" = yes
 905 then
 906         AC_CHECKING([for $CC __attribute__ directives])
 907 cat > conftest.$ac_ext <<EOF
 908 #line __oline__ "${as_me:-configure}"
 909 #include "confdefs.h"
 910 #include "conftest.h"
 911 #include "conftest.i"
 912 #if     GCC_PRINTF
 913 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
 914 #else
 915 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
 916 #endif
 917 #if     GCC_SCANF
 918 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
 919 #else
 920 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
 921 #endif
 922 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
 923 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
 924 extern void foo(void) GCC_NORETURN;
 925 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
 926 EOF
 927         cf_printf_attribute=no
 928         cf_scanf_attribute=no
 929         for cf_attribute in scanf printf unused noreturn
 930         do
 931                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
 932                 cf_directive="__attribute__(($cf_attribute))"
 933                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
 934
 935                 case $cf_attribute in #(vi
 936                 printf) #(vi
 937                         cf_printf_attribute=yes
 938                         cat >conftest.h <<EOF
 939 #define GCC_$cf_ATTRIBUTE 1
 940 EOF
 941                         ;;
 942                 scanf) #(vi
 943                         cf_scanf_attribute=yes
 944                         cat >conftest.h <<EOF
 945 #define GCC_$cf_ATTRIBUTE 1
 946 EOF
 947                         ;;
 948                 *) #(vi
 949                         cat >conftest.h <<EOF
 950 #define GCC_$cf_ATTRIBUTE $cf_directive
 951 EOF
 952                         ;;
 953                 esac
 954
 955                 if AC_TRY_EVAL(ac_compile); then
 956                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
 957                         cat conftest.h >>confdefs.h
 958                         case $cf_attribute in #(vi
 959                         printf) #(vi
 960                                 if test "$cf_printf_attribute" = no ; then
 961                                         cat >>confdefs.h <<EOF
 962 #define GCC_PRINTFLIKE(fmt,var) /* nothing */
 963 EOF
 964                                 else
 965                                         cat >>confdefs.h <<EOF
 966 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
 967 EOF
 968                                 fi
 969                                 ;;
 970                         scanf) #(vi
 971                                 if test "$cf_scanf_attribute" = no ; then
 972                                         cat >>confdefs.h <<EOF
 973 #define GCC_SCANFLIKE(fmt,var) /* nothing */
 974 EOF
 975                                 else
 976                                         cat >>confdefs.h <<EOF
 977 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
 978 EOF
 979                                 fi
 980                                 ;;
 981                         esac
 982                 fi
 983         done
 984 else
 985         fgrep define conftest.i >>confdefs.h
 986 fi
 987 rm -rf conftest*
 988 fi
 989 ])dnl
 990 dnl ---------------------------------------------------------------------------
 991 dnl CF_GCC_VERSION version: 5 updated: 2010/04/24 11:02:31
 992 dnl --------------
 993 dnl Find version of gcc
 994 AC_DEFUN([CF_GCC_VERSION],[
 995 AC_REQUIRE([AC_PROG_CC])
 996 GCC_VERSION=none
 997 if test "$GCC" = yes ; then
 998         AC_MSG_CHECKING(version of $CC)
 999         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1000         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1001         AC_MSG_RESULT($GCC_VERSION)
1002 fi
1003 ])dnl
1004 dnl ---------------------------------------------------------------------------
1005 dnl CF_GCC_WARNINGS version: 27 updated: 2010/10/23 15:52:32
1006 dnl ---------------
1007 dnl Check if the compiler supports useful warning options.  There's a few that
1008 dnl we don't use, simply because they're too noisy:
1009 dnl
1010 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1011 dnl     -Wredundant-decls (system headers make this too noisy)
1012 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1013 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1014 dnl             is enabled for ncurses using "--enable-const".
1015 dnl     -pedantic
1016 dnl
1017 dnl Parameter:
1018 dnl     $1 is an optional list of gcc warning flags that a particular
1019 dnl             application might want to use, e.g., "no-unused" for
1020 dnl             -Wno-unused
1021 dnl Special:
1022 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1023 dnl
1024 AC_DEFUN([CF_GCC_WARNINGS],
1025 [
1026 AC_REQUIRE([CF_GCC_VERSION])
1027 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1028
1029 cat > conftest.$ac_ext <<EOF
1030 #line __oline__ "${as_me:-configure}"
1031 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1032 EOF
1033
1034 if test "$INTEL_COMPILER" = yes
1035 then
1036 # The "-wdXXX" options suppress warnings:
1037 # remark #1419: external declaration in primary source file
1038 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1039 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1040 # remark #193: zero used for undefined preprocessing identifier
1041 # remark #593: variable "curs_sb_left_arrow" was set but never used
1042 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1043 # remark #869: parameter "tw" was never referenced
1044 # remark #981: operands are evaluated in unspecified order
1045 # warning #279: controlling expression is constant
1046
1047         AC_CHECKING([for $CC warning options])
1048         cf_save_CFLAGS="$CFLAGS"
1049         EXTRA_CFLAGS="-Wall"
1050         for cf_opt in \
1051                 wd1419 \
1052                 wd1683 \
1053                 wd1684 \
1054                 wd193 \
1055                 wd593 \
1056                 wd279 \
1057                 wd810 \
1058                 wd869 \
1059                 wd981
1060         do
1061                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1062                 if AC_TRY_EVAL(ac_compile); then
1063                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1064                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1065                 fi
1066         done
1067         CFLAGS="$cf_save_CFLAGS"
1068
1069 elif test "$GCC" = yes
1070 then
1071         AC_CHECKING([for $CC warning options])
1072         cf_save_CFLAGS="$CFLAGS"
1073         EXTRA_CFLAGS=
1074         cf_warn_CONST=""
1075         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1076         for cf_opt in W Wall \
1077                 Wbad-function-cast \
1078                 Wcast-align \
1079                 Wcast-qual \
1080                 Winline \
1081                 Wmissing-declarations \
1082                 Wmissing-prototypes \
1083                 Wnested-externs \
1084                 Wpointer-arith \
1085                 Wshadow \
1086                 Wstrict-prototypes \
1087                 Wundef $cf_warn_CONST $1
1088         do
1089                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1090                 if AC_TRY_EVAL(ac_compile); then
1091                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1092                         case $cf_opt in #(vi
1093                         Wcast-qual) #(vi
1094                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1095                                 ;;
1096                         Winline) #(vi
1097                                 case $GCC_VERSION in
1098                                 [[34]].*)
1099                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1100                                         continue;;
1101                                 esac
1102                                 ;;
1103                         esac
1104                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1105                 fi
1106         done
1107         CFLAGS="$cf_save_CFLAGS"
1108 fi
1109 rm -rf conftest*
1110
1111 AC_SUBST(EXTRA_CFLAGS)
1112 ])dnl
1113 dnl ---------------------------------------------------------------------------
1114 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
1115 dnl ----------------
1116 AC_DEFUN([CF_GNAT_GENERICS],
1117 [
1118 AC_REQUIRE([CF_GNAT_VERSION])
1119
1120 AC_MSG_CHECKING(if GNAT supports generics)
1121 case $cf_gnat_version in #(vi
1122 3.[[1-9]]*|[[4-9]].*) #(vi
1123         cf_gnat_generics=yes
1124         ;;
1125 *)
1126         cf_gnat_generics=no
1127         ;;
1128 esac
1129 AC_MSG_RESULT($cf_gnat_generics)
1130
1131 if test "$cf_gnat_generics" = yes
1132 then
1133         cf_compile_generics=generics
1134         cf_generic_objects="\${GENOBJS}"
1135 else
1136         cf_compile_generics=
1137         cf_generic_objects=
1138 fi
1139
1140 AC_SUBST(cf_compile_generics)
1141 AC_SUBST(cf_generic_objects)
1142 ])dnl
1143 dnl ---------------------------------------------------------------------------
1144 dnl CF_GNAT_PRAGMA_UNREF version: 1 updated: 2010/06/19 15:22:18
1145 dnl --------------------
1146 dnl Check if the gnat pragma "Unreferenced" works.
1147 AC_DEFUN([CF_GNAT_PRAGMA_UNREF],[
1148 AC_CACHE_CHECK(if GNAT pragma Unreferenced works,cf_cv_pragma_unreferenced,[
1149 CF_GNAT_TRY_LINK([procedure conftest;],
1150 [with Text_IO;
1151 with GNAT.OS_Lib;
1152 procedure conftest is
1153    test : Integer;
1154    pragma Unreferenced (test);
1155 begin
1156    test := 1;
1157    Text_IO.Put ("Hello World");
1158    Text_IO.New_Line;
1159    GNAT.OS_Lib.OS_Exit (0);
1160 end conftest;],
1161         [cf_cv_pragma_unreferenced=yes],
1162         [cf_cv_pragma_unreferenced=no])])
1163
1164 # if the pragma is supported, use it (needed in the Trace code).
1165 if test $cf_cv_pragma_unreferenced = yes ; then
1166         PRAGMA_UNREF=TRUE
1167 else
1168         PRAGMA_UNREF=FALSE
1169 fi
1170 AC_SUBST(PRAGMA_UNREF)
1171 ])dnl
1172 dnl ---------------------------------------------------------------------------
1173 dnl CF_GNAT_PROJECTS version: 2 updated: 2011/03/23 20:24:41
1174 dnl ----------------
1175 dnl GNAT projects are configured with ".gpr" project files.
1176 dnl GNAT libraries are a further development, using the project feature.
1177 AC_DEFUN([CF_GNAT_PROJECTS],
1178 [
1179 AC_REQUIRE([CF_GNAT_VERSION])
1180
1181 cf_gnat_libraries=no
1182 cf_gnat_projects=no
1183
1184 AC_MSG_CHECKING(if GNAT supports project files)
1185 case $cf_gnat_version in #(vi
1186 3.[[0-9]]*) #(vi
1187         ;;
1188 *)
1189         case $cf_cv_system_name in #(vi
1190         cygwin*) #(vi
1191                 ;;
1192         *)
1193                 mkdir conftest.src conftest.bin conftest.lib
1194                 cd conftest.src
1195                 rm -rf conftest* *~conftest*
1196                 cat >>library.gpr <<CF_EOF
1197 project Library is
1198   Kind := External ("LIB_KIND");
1199   for Library_Name use "ConfTest";
1200   for Object_Dir use ".";
1201   for Library_ALI_Dir use External("LIBRARY_DIR");
1202   for Library_Version use External ("SONAME");
1203   for Library_Kind use Kind;
1204   for Library_Dir use External("BUILD_DIR");
1205   Source_Dir := External ("SOURCE_DIR");
1206   for Source_Dirs use (Source_Dir);
1207   package Compiler is
1208      for Default_Switches ("Ada") use
1209        ("-g",
1210         "-O2",
1211         "-gnatafno",
1212         "-gnatVa",   -- All validity checks
1213         "-gnatwa");  -- Activate all optional errors
1214   end Compiler;
1215 end Library;
1216 CF_EOF
1217                 cat >>confpackage.ads <<CF_EOF
1218 package ConfPackage is
1219    procedure conftest;
1220 end ConfPackage;
1221 CF_EOF
1222                 cat >>confpackage.adb <<CF_EOF
1223 with Text_IO;
1224 package body ConfPackage is
1225    procedure conftest is
1226    begin
1227       Text_IO.Put ("Hello World");
1228       Text_IO.New_Line;
1229    end conftest;
1230 end ConfPackage;
1231 CF_EOF
1232                 if ( $cf_ada_make $ADAFLAGS \
1233                                 -Plibrary.gpr \
1234                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
1235                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
1236                                 -XSOURCE_DIR=`pwd` \
1237                                 -XSONAME=libConfTest.so.1 \
1238                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
1239                         cf_gnat_projects=yes
1240                 fi
1241                 cd ..
1242                 if test -f conftest.lib/confpackage.ali
1243                 then
1244                         cf_gnat_libraries=yes
1245                 fi
1246                 rm -rf conftest* *~conftest*
1247                 ;;
1248         esac
1249         ;;
1250 esac
1251 AC_MSG_RESULT($cf_gnat_projects)
1252
1253 if test $cf_gnat_projects = yes
1254 then
1255         AC_MSG_CHECKING(if GNAT supports libraries)
1256         AC_MSG_RESULT($cf_gnat_libraries)
1257 fi
1258
1259 if test "$cf_gnat_projects" = yes
1260 then
1261         USE_OLD_MAKERULES="#"
1262         USE_GNAT_PROJECTS=""
1263 else
1264         USE_OLD_MAKERULES=""
1265         USE_GNAT_PROJECTS="#"
1266 fi
1267
1268 if test "$cf_gnat_libraries" = yes
1269 then
1270         USE_GNAT_LIBRARIES=""
1271 else
1272         USE_GNAT_LIBRARIES="#"
1273 fi
1274
1275 AC_SUBST(USE_OLD_MAKERULES)
1276 AC_SUBST(USE_GNAT_PROJECTS)
1277 AC_SUBST(USE_GNAT_LIBRARIES)
1278 ])dnl
1279 dnl ---------------------------------------------------------------------------
1280 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
1281 dnl --------------
1282 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
1283 dnl is noted that gnat may compile a tasking unit even for configurations which
1284 dnl fail at runtime.
1285 AC_DEFUN([CF_GNAT_SIGINT],[
1286 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
1287 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
1288
1289 package ConfTest is
1290
1291    pragma Warnings (Off);  --  the next pragma exists since 3.11p
1292    pragma Unreserve_All_Interrupts;
1293    pragma Warnings (On);
1294
1295    protected Process is
1296       procedure Stop;
1297       function Continue return Boolean;
1298       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
1299    private
1300       Done : Boolean := False;
1301    end Process;
1302
1303 end ConfTest;],
1304 [package body ConfTest is
1305    protected body Process is
1306       procedure Stop is
1307       begin
1308          Done := True;
1309       end Stop;
1310       function Continue return Boolean is
1311       begin
1312          return not Done;
1313       end Continue;
1314    end Process;
1315 end ConfTest;],
1316         [cf_cv_gnat_sigint=yes],
1317         [cf_cv_gnat_sigint=no])])
1318
1319 if test $cf_cv_gnat_sigint = yes ; then
1320         USE_GNAT_SIGINT=""
1321 else
1322         USE_GNAT_SIGINT="#"
1323 fi
1324 AC_SUBST(USE_GNAT_SIGINT)
1325 ])dnl
1326 dnl ---------------------------------------------------------------------------
1327 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
1328 dnl ----------------
1329 dnl Verify that a test program compiles/links with GNAT.
1330 dnl $cf_ada_make is set to the program that compiles/links
1331 dnl $ADAFLAGS may be set to the GNAT flags.
1332 dnl
1333 dnl $1 is the text of the spec
1334 dnl $2 is the text of the body
1335 dnl $3 is the shell command to execute if successful
1336 dnl $4 is the shell command to execute if not successful
1337 AC_DEFUN([CF_GNAT_TRY_LINK],
1338 [
1339 rm -rf conftest* *~conftest*
1340 cat >>conftest.ads <<CF_EOF
1341 $1
1342 CF_EOF
1343 cat >>conftest.adb <<CF_EOF
1344 $2
1345 CF_EOF
1346 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1347 ifelse($3,,      :,[      $3])
1348 ifelse($4,,,[else
1349    $4])
1350 fi
1351 rm -rf conftest* *~conftest*
1352 ])dnl
1353 dnl ---------------------------------------------------------------------------
1354 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
1355 dnl ---------------
1356 dnl Verify that a test program compiles and runs with GNAT
1357 dnl $cf_ada_make is set to the program that compiles/links
1358 dnl $ADAFLAGS may be set to the GNAT flags.
1359 dnl
1360 dnl $1 is the text of the spec
1361 dnl $2 is the text of the body
1362 dnl $3 is the shell command to execute if successful
1363 dnl $4 is the shell command to execute if not successful
1364 AC_DEFUN([CF_GNAT_TRY_RUN],
1365 [
1366 rm -rf conftest* *~conftest*
1367 cat >>conftest.ads <<CF_EOF
1368 $1
1369 CF_EOF
1370 cat >>conftest.adb <<CF_EOF
1371 $2
1372 CF_EOF
1373 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1374    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1375 ifelse($3,,      :,[      $3])
1376 ifelse($4,,,[   else
1377       $4])
1378    fi
1379 ifelse($4,,,[else
1380    $4])
1381 fi
1382 rm -rf conftest* *~conftest*
1383 ])dnl
1384 dnl ---------------------------------------------------------------------------
1385 dnl CF_GNAT_VERSION version: 18 updated: 2012/01/21 19:28:10
1386 dnl ---------------
1387 dnl Verify version of GNAT.
1388 AC_DEFUN([CF_GNAT_VERSION],
1389 [
1390 AC_MSG_CHECKING(for gnat version)
1391 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
1392         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1393     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1394 AC_MSG_RESULT($cf_gnat_version)
1395
1396 case $cf_gnat_version in #(vi
1397 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]]) #(vi
1398         cf_cv_prog_gnat_correct=yes
1399         ;;
1400 *)
1401         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1402         cf_cv_prog_gnat_correct=no
1403         ;;
1404 esac
1405 ])
1406 dnl ---------------------------------------------------------------------------
1407 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
1408 dnl -------------
1409 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1410 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1411 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1412 dnl since it is interwoven with GNU extensions.
1413 dnl
1414 dnl Well, yes we could work around it...
1415 AC_DEFUN([CF_GNU_SOURCE],
1416 [
1417 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1418 AC_TRY_COMPILE([#include <sys/types.h>],[
1419 #ifndef _XOPEN_SOURCE
1420 make an error
1421 #endif],
1422         [cf_cv_gnu_source=no],
1423         [cf_save="$CPPFLAGS"
1424          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1425          AC_TRY_COMPILE([#include <sys/types.h>],[
1426 #ifdef _XOPEN_SOURCE
1427 make an error
1428 #endif],
1429         [cf_cv_gnu_source=no],
1430         [cf_cv_gnu_source=yes])
1431         CPPFLAGS="$cf_save"
1432         ])
1433 ])
1434 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1435 ])dnl
1436 dnl ---------------------------------------------------------------------------
1437 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
1438 dnl --------------
1439 dnl Construct a search-list of directories for a nonstandard header-file
1440 dnl
1441 dnl Parameters
1442 dnl     $1 = the variable to return as result
1443 dnl     $2 = the package name
1444 AC_DEFUN([CF_HEADER_PATH],
1445 [
1446 $1=
1447
1448 # collect the current set of include-directories from compiler flags
1449 cf_header_path_list=""
1450 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1451         for cf_header_path in $CPPFLAGS $CFLAGS
1452         do
1453                 case $cf_header_path in #(vi
1454                 -I*)
1455                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1456                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1457                         cf_header_path_list="$cf_header_path_list [$]$1"
1458                         ;;
1459                 esac
1460         done
1461 fi
1462
1463 # add the variations for the package we are looking for
1464 CF_SUBDIR_PATH($1,$2,include)
1465
1466 test "$includedir" != NONE && \
1467 test "$includedir" != "/usr/include" && \
1468 test -d "$includedir" && {
1469         test -d $includedir &&    $1="[$]$1 $includedir"
1470         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1471 }
1472
1473 test "$oldincludedir" != NONE && \
1474 test "$oldincludedir" != "/usr/include" && \
1475 test -d "$oldincludedir" && {
1476         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1477         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1478 }
1479
1480 $1="[$]$1 $cf_header_path_list"
1481 ])dnl
1482 dnl ---------------------------------------------------------------------------
1483 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
1484 dnl ---------------
1485 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1486 AC_DEFUN([CF_HELP_MESSAGE],
1487 [AC_DIVERT_HELP([$1])dnl
1488 ])dnl
1489 dnl ---------------------------------------------------------------------------
1490 dnl CF_INCLUDE_DIRS version: 6 updated: 2009/01/06 19:37:40
1491 dnl ---------------
1492 dnl Construct the list of include-options according to whether we're building
1493 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
1494 dnl with gcc, don't append the includedir if it happens to be /usr/include,
1495 dnl since that usually breaks gcc's shadow-includes.
1496 AC_DEFUN([CF_INCLUDE_DIRS],
1497 [
1498 CPPFLAGS="$CPPFLAGS -I. -I../include"
1499 if test "$srcdir" != "."; then
1500         CPPFLAGS="$CPPFLAGS -I\${srcdir}/../include"
1501 fi
1502 if test "$GCC" != yes; then
1503         CPPFLAGS="$CPPFLAGS -I\${includedir}"
1504 elif test "$includedir" != "/usr/include"; then
1505         if test "$includedir" = '${prefix}/include' ; then
1506                 if test $prefix != /usr ; then
1507                         CPPFLAGS="$CPPFLAGS -I\${includedir}"
1508                 fi
1509         else
1510                 CPPFLAGS="$CPPFLAGS -I\${includedir}"
1511         fi
1512 fi
1513 AC_SUBST(CPPFLAGS)
1514 ])dnl
1515 dnl ---------------------------------------------------------------------------
1516 dnl CF_INTEL_COMPILER version: 4 updated: 2010/05/26 05:38:42
1517 dnl -----------------
1518 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1519 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1520 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1521 dnl
1522 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1523 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1524 dnl the wrappers for gcc and g++ warnings.
1525 dnl
1526 dnl $1 = GCC (default) or GXX
1527 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1528 dnl $3 = CFLAGS (default) or CXXFLAGS
1529 AC_DEFUN([CF_INTEL_COMPILER],[
1530 ifelse([$2],,INTEL_COMPILER,[$2])=no
1531
1532 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1533         case $host_os in
1534         linux*|gnu*)
1535                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1536                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1537                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1538                 AC_TRY_COMPILE([],[
1539 #ifdef __INTEL_COMPILER
1540 #else
1541 make an error
1542 #endif
1543 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1544 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
1545 ],[])
1546                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1547                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1548                 ;;
1549         esac
1550 fi
1551 ])dnl
1552 dnl ---------------------------------------------------------------------------
1553 dnl CF_LARGEFILE version: 7 updated: 2007/06/02 11:58:50
1554 dnl ------------
1555 dnl Add checks for large file support.
1556 AC_DEFUN([CF_LARGEFILE],[
1557 ifdef([AC_FUNC_FSEEKO],[
1558     AC_SYS_LARGEFILE
1559     if test "$enable_largefile" != no ; then
1560         AC_FUNC_FSEEKO
1561
1562         # Normally we would collect these definitions in the config.h,
1563         # but (like _XOPEN_SOURCE), some environments rely on having these
1564         # defined before any of the system headers are included.  Another
1565         # case comes up with C++, e.g., on AIX the compiler compiles the
1566         # header files by themselves before looking at the body files it is
1567         # told to compile.  For ncurses, those header files do not include
1568         # the config.h
1569         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
1570         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
1571         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
1572
1573         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
1574                 AC_TRY_COMPILE([
1575 #include <sys/types.h>
1576 #include <dirent.h>
1577                 ],[
1578                 /* if transitional largefile support is setup, this is true */
1579                 extern struct dirent64 * readdir(DIR *);
1580                 struct dirent64 *x = readdir((DIR *)0);
1581                 struct dirent *y = readdir((DIR *)0);
1582                 int z = x - y;
1583                 ],
1584                 [cf_cv_struct_dirent64=yes],
1585                 [cf_cv_struct_dirent64=no])
1586         ])
1587         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64)
1588     fi
1589 ])
1590 ])
1591 dnl ---------------------------------------------------------------------------
1592 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
1593 dnl ---------------
1594 dnl For the given system and compiler, find the compiler flags to pass to the
1595 dnl loader to use the "rpath" feature.
1596 AC_DEFUN([CF_LD_RPATH_OPT],
1597 [
1598 AC_REQUIRE([CF_CHECK_CACHE])
1599
1600 LD_RPATH_OPT=
1601 AC_MSG_CHECKING(for an rpath option)
1602 case $cf_cv_system_name in #(vi
1603 irix*) #(vi
1604         if test "$GCC" = yes; then
1605                 LD_RPATH_OPT="-Wl,-rpath,"
1606         else
1607                 LD_RPATH_OPT="-rpath "
1608         fi
1609         ;;
1610 linux*|gnu*|k*bsd*-gnu) #(vi
1611         LD_RPATH_OPT="-Wl,-rpath,"
1612         ;;
1613 openbsd[[2-9]].*|mirbsd*) #(vi
1614         LD_RPATH_OPT="-Wl,-rpath,"
1615         ;;
1616 dragonfly*|freebsd*) #(vi
1617         LD_RPATH_OPT="-rpath "
1618         ;;
1619 netbsd*) #(vi
1620         LD_RPATH_OPT="-Wl,-rpath,"
1621         ;;
1622 osf*|mls+*) #(vi
1623         LD_RPATH_OPT="-rpath "
1624         ;;
1625 solaris2*) #(vi
1626         LD_RPATH_OPT="-R"
1627         ;;
1628 *)
1629         ;;
1630 esac
1631 AC_MSG_RESULT($LD_RPATH_OPT)
1632
1633 case "x$LD_RPATH_OPT" in #(vi
1634 x-R*)
1635         AC_MSG_CHECKING(if we need a space after rpath option)
1636         cf_save_LIBS="$LIBS"
1637         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1638         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1639         LIBS="$cf_save_LIBS"
1640         AC_MSG_RESULT($cf_rpath_space)
1641         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1642         ;;
1643 esac
1644 ])dnl
1645 dnl ---------------------------------------------------------------------------
1646 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
1647 dnl ---------------
1648 dnl Construct a search-list of directories for a nonstandard library-file
1649 dnl
1650 dnl Parameters
1651 dnl     $1 = the variable to return as result
1652 dnl     $2 = the package name
1653 AC_DEFUN([CF_LIBRARY_PATH],
1654 [
1655 $1=
1656 cf_library_path_list=""
1657 if test -n "${LDFLAGS}${LIBS}" ; then
1658         for cf_library_path in $LDFLAGS $LIBS
1659         do
1660                 case $cf_library_path in #(vi
1661                 -L*)
1662                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1663                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1664                         cf_library_path_list="$cf_library_path_list [$]$1"
1665                         ;;
1666                 esac
1667         done
1668 fi
1669
1670 CF_SUBDIR_PATH($1,$2,lib)
1671
1672 $1="$cf_library_path_list [$]$1"
1673 ])dnl
1674 dnl ---------------------------------------------------------------------------
1675 dnl CF_LIB_PREFIX version: 9 updated: 2012/01/21 19:28:10
1676 dnl -------------
1677 dnl Compute the library-prefix for the given host system
1678 dnl $1 = variable to set
1679 define([CF_LIB_PREFIX],
1680 [
1681         case $cf_cv_system_name in #(vi
1682         OS/2*|os2*) #(vi
1683         LIB_PREFIX=''
1684         ;;
1685         *)      LIB_PREFIX='lib'
1686         ;;
1687         esac
1688 ifelse($1,,,[$1=$LIB_PREFIX])
1689         AC_SUBST(LIB_PREFIX)
1690 ])dnl
1691 dnl ---------------------------------------------------------------------------
1692 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
1693 dnl -------------
1694 dnl Find the and soname for the given shared library.  Set the cache variable
1695 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
1696 dnl variable to "unknown".
1697 dnl
1698 dnl $1 = headers
1699 dnl $2 = code
1700 dnl $3 = library name
1701 AC_DEFUN([CF_LIB_SONAME],
1702 [
1703 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
1704
1705 cf_cv_$3_soname=unknown
1706 if test "$cross_compiling" != yes ; then
1707 cat >conftest.$ac_ext <<CF_EOF
1708 $1
1709 int main()
1710 {
1711 $2
1712         ${cf_cv_main_return:-return}(0);
1713 }
1714 CF_EOF
1715 cf_save_LIBS="$LIBS"
1716         CF_ADD_LIB($3)
1717         if AC_TRY_EVAL(ac_compile) ; then
1718                 if AC_TRY_EVAL(ac_link) ; then
1719                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
1720                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
1721                 fi
1722         fi
1723 rm -rf conftest*
1724 LIBS="$cf_save_LIBS"
1725 fi
1726 ])
1727 ])
1728 dnl ---------------------------------------------------------------------------
1729 dnl CF_LIB_SUFFIX version: 17 updated: 2011/07/02 15:36:04
1730 dnl -------------
1731 dnl Compute the library file-suffix from the given model name
1732 dnl $1 = model name
1733 dnl $2 = variable to set (the nominal library suffix)
1734 dnl $3 = dependency variable to set (actual filename)
1735 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1736 AC_DEFUN([CF_LIB_SUFFIX],
1737 [
1738         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
1739         case $1 in #(vi
1740         libtool) #(vi
1741                 $2='.la'
1742                 $3=[$]$2
1743                 ;;
1744         normal) #(vi
1745                 $2='.a'
1746                 $3=[$]$2
1747                 ;;
1748         debug) #(vi
1749                 $2='_g.a'
1750                 $3=[$]$2
1751                 ;;
1752         profile) #(vi
1753                 $2='_p.a'
1754                 $3=[$]$2
1755                 ;;
1756         shared) #(vi
1757                 case $cf_cv_system_name in
1758                 aix[[5-7]]*) #(vi
1759                         $2='.a'
1760                         $3=[$]$2
1761                         ;;
1762                 cygwin*) #(vi
1763                         $2='.dll'
1764                         $3='.dll.a'
1765                         ;;
1766                 darwin*) #(vi
1767                         $2='.dylib'
1768                         $3=[$]$2
1769                         ;;
1770                 hpux*) #(vi
1771                         case $target in
1772                         ia64*) #(vi
1773                                 $2='.so'
1774                                 $3=[$]$2
1775                                 ;;
1776                         *) #(vi
1777                                 $2='.sl'
1778                                 $3=[$]$2
1779                                 ;;
1780                         esac
1781                         ;;
1782                 *)      $2='.so'
1783                         $3=[$]$2
1784                         ;;
1785                 esac
1786         esac
1787         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
1788         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
1789 ])dnl
1790 dnl ---------------------------------------------------------------------------
1791 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
1792 dnl -----------
1793 dnl Compute the string to append to -library from the given model name
1794 dnl $1 = model name
1795 dnl $2 = variable to set
1796 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1797 AC_DEFUN([CF_LIB_TYPE],
1798 [
1799         case $1 in
1800         libtool) $2=''   ;;
1801         normal)  $2=''   ;;
1802         debug)   $2='_g' ;;
1803         profile) $2='_p' ;;
1804         shared)  $2=''   ;;
1805         esac
1806         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
1807 ])dnl
1808 dnl ---------------------------------------------------------------------------
1809 dnl CF_LINK_DATAONLY version: 9 updated: 2009/01/01 20:21:38
1810 dnl ----------------
1811 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
1812 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
1813 dnl have to provide wrappers for global tables to ensure they're linked
1814 dnl properly.
1815 AC_DEFUN([CF_LINK_DATAONLY],
1816 [
1817 AC_MSG_CHECKING([if data-only library module links])
1818 AC_CACHE_VAL(cf_cv_link_dataonly,[
1819         rm -f conftest.a
1820         cat >conftest.$ac_ext <<EOF
1821 #line __oline__ "configure"
1822 int     testdata[[3]] = { 123, 456, 789 };
1823 EOF
1824         if AC_TRY_EVAL(ac_compile) ; then
1825                 mv conftest.o data.o && \
1826                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
1827         fi
1828         rm -f conftest.$ac_ext data.o
1829         cat >conftest.$ac_ext <<EOF
1830 #line __oline__ "configure"
1831 int     testfunc()
1832 {
1833 #if defined(NeXT)
1834         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
1835 #else
1836         extern int testdata[[3]];
1837         return testdata[[0]] == 123
1838            &&  testdata[[1]] == 456
1839            &&  testdata[[2]] == 789;
1840 #endif
1841 }
1842 EOF
1843         if AC_TRY_EVAL(ac_compile); then
1844                 mv conftest.o func.o && \
1845                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
1846         fi
1847         rm -f conftest.$ac_ext func.o
1848         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
1849         cf_saveLIBS="$LIBS"
1850         LIBS="conftest.a $LIBS"
1851         AC_TRY_RUN([
1852         int main()
1853         {
1854                 extern int testfunc();
1855                 ${cf_cv_main_return:-return} (!testfunc());
1856         }
1857         ],
1858         [cf_cv_link_dataonly=yes],
1859         [cf_cv_link_dataonly=no],
1860         [cf_cv_link_dataonly=unknown])
1861         LIBS="$cf_saveLIBS"
1862         ])
1863 AC_MSG_RESULT($cf_cv_link_dataonly)
1864
1865 if test "$cf_cv_link_dataonly" = no ; then
1866         AC_DEFINE(BROKEN_LINKER)
1867         BROKEN_LINKER=1
1868 fi
1869
1870 ])dnl
1871 dnl ---------------------------------------------------------------------------
1872 dnl CF_LINK_FUNCS version: 7 updated: 2006/12/16 12:33:30
1873 dnl -------------
1874 dnl Most Unix systems have both link and symlink, a few don't have symlink.
1875 dnl A few non-Unix systems implement symlink, but not link.
1876 dnl A few non-systems implement neither (or have nonfunctional versions).
1877 AC_DEFUN([CF_LINK_FUNCS],
1878 [
1879 AC_CHECK_FUNCS( \
1880         remove \
1881         unlink )
1882
1883 if test "$cross_compiling" = yes ; then
1884         AC_CHECK_FUNCS( \
1885                 link \
1886                 symlink )
1887 else
1888         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
1889                 cf_cv_link_funcs=
1890                 for cf_func in link symlink ; do
1891                         AC_TRY_RUN([
1892 #include <sys/types.h>
1893 #include <sys/stat.h>
1894 #ifdef HAVE_UNISTD_H
1895 #include <unistd.h>
1896 #endif
1897 int main()
1898 {
1899         int fail = 0;
1900         char *src = "config.log";
1901         char *dst = "conftest.chk";
1902         struct stat src_sb;
1903         struct stat dst_sb;
1904
1905         stat(src, &src_sb);
1906         fail = ($cf_func("config.log", "conftest.chk") < 0)
1907             || (stat(dst, &dst_sb) < 0)
1908             || (dst_sb.st_mtime != src_sb.st_mtime);
1909 #ifdef HAVE_UNLINK
1910         unlink(dst);
1911 #else
1912         remove(dst);
1913 #endif
1914         ${cf_cv_main_return:-return} (fail);
1915 }
1916                         ],[
1917                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
1918                         eval 'ac_cv_func_'$cf_func'=yes'],[
1919                         eval 'ac_cv_func_'$cf_func'=no'],[
1920                         eval 'ac_cv_func_'$cf_func'=error'])
1921                 done
1922                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
1923         ])
1924         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK)
1925         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK)
1926 fi
1927 ])dnl
1928 dnl ---------------------------------------------------------------------------
1929 dnl CF_MAIN_RETURN version: 1 updated: 2006/12/10 09:51:54
1930 dnl --------------
1931 dnl Check if a return from main to the shell actually returns the same exit
1932 dnl code.  This is true for almost any POSIX environment.
1933 dnl
1934 dnl Some very old environments did not flush stdout, etc., on an exit.  That
1935 dnl would be a useful case to test for also.
1936 AC_DEFUN([CF_MAIN_RETURN],
1937 [
1938 cf_cv_main_return=return
1939 ])dnl
1940 dnl ---------------------------------------------------------------------------
1941 dnl CF_MAKEFLAGS version: 14 updated: 2011/03/31 19:29:46
1942 dnl ------------
1943 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
1944 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
1945 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
1946 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
1947 AC_DEFUN([CF_MAKEFLAGS],
1948 [
1949 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
1950         cf_cv_makeflags=''
1951         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
1952         do
1953                 cat >cf_makeflags.tmp <<CF_EOF
1954 SHELL = /bin/sh
1955 all :
1956         @ echo '.$cf_option'
1957 CF_EOF
1958                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
1959                 case "$cf_result" in
1960                 .*k)
1961                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
1962                         case "$cf_result" in
1963                         .*CC=*) cf_cv_makeflags=
1964                                 ;;
1965                         *)      cf_cv_makeflags=$cf_option
1966                                 ;;
1967                         esac
1968                         break
1969                         ;;
1970                 .-)     ;;
1971                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
1972                         ;;
1973                 esac
1974         done
1975         rm -f cf_makeflags.tmp
1976 ])
1977
1978 AC_SUBST(cf_cv_makeflags)
1979 ])dnl
1980 dnl ---------------------------------------------------------------------------
1981 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
1982 dnl ------------
1983 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
1984 dnl a monocase filesystem.
1985 AC_DEFUN([CF_MAKE_TAGS],[
1986 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
1987
1988 AC_CHECK_PROGS(CTAGS, exctags ctags)
1989 AC_CHECK_PROGS(ETAGS, exetags etags)
1990
1991 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
1992
1993 if test "$cf_cv_mixedcase" = yes ; then
1994         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
1995 else
1996         MAKE_UPPER_TAGS=no
1997 fi
1998
1999 if test "$MAKE_UPPER_TAGS" = yes ; then
2000         MAKE_UPPER_TAGS=
2001 else
2002         MAKE_UPPER_TAGS="#"
2003 fi
2004
2005 if test "$MAKE_LOWER_TAGS" = yes ; then
2006         MAKE_LOWER_TAGS=
2007 else
2008         MAKE_LOWER_TAGS="#"
2009 fi
2010
2011 AC_SUBST(CTAGS)
2012 AC_SUBST(ETAGS)
2013
2014 AC_SUBST(MAKE_UPPER_TAGS)
2015 AC_SUBST(MAKE_LOWER_TAGS)
2016 ])dnl
2017 dnl ---------------------------------------------------------------------------
2018 dnl CF_MIXEDCASE_FILENAMES version: 3 updated: 2003/09/20 17:07:55
2019 dnl ----------------------
2020 dnl Check if the file-system supports mixed-case filenames.  If we're able to
2021 dnl create a lowercase name and see it as uppercase, it doesn't support that.
2022 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
2023 [
2024 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2025 if test "$cross_compiling" = yes ; then
2026         case $target_alias in #(vi
2027         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-mingw32*|*-uwin*) #(vi
2028                 cf_cv_mixedcase=no
2029                 ;;
2030         *)
2031                 cf_cv_mixedcase=yes
2032                 ;;
2033         esac
2034 else
2035         rm -f conftest CONFTEST
2036         echo test >conftest
2037         if test -f CONFTEST ; then
2038                 cf_cv_mixedcase=no
2039         else
2040                 cf_cv_mixedcase=yes
2041         fi
2042         rm -f conftest CONFTEST
2043 fi
2044 ])
2045 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES)
2046 ])dnl
2047 dnl ---------------------------------------------------------------------------
2048 dnl CF_MKSTEMP version: 8 updated: 2012/02/13 20:34:56
2049 dnl ----------
2050 dnl Check for a working mkstemp.  This creates two files, checks that they are
2051 dnl successfully created and distinct (AmigaOS apparently fails on the last).
2052 AC_DEFUN([CF_MKSTEMP],[
2053 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
2054 rm -rf conftest*
2055 AC_TRY_RUN([
2056 #include <sys/types.h>
2057 #include <stdlib.h>
2058 #include <stdio.h>
2059 #include <string.h>
2060 #include <sys/stat.h>
2061 int main()
2062 {
2063         char *tmpl = "conftestXXXXXX";
2064         char name[2][80];
2065         int n;
2066         int result = 0;
2067         int fd;
2068         struct stat sb;
2069
2070         umask(077);
2071         for (n = 0; n < 2; ++n) {
2072                 strcpy(name[n], tmpl);
2073                 if ((fd = mkstemp(name[n])) >= 0) {
2074                         if (!strcmp(name[n], tmpl)
2075                          || stat(name[n], &sb) != 0
2076                          || (sb.st_mode & S_IFMT) != S_IFREG
2077                          || (sb.st_mode & 077) != 0) {
2078                                 result = 1;
2079                         }
2080                         close(fd);
2081                 }
2082         }
2083         if (result == 0
2084          && !strcmp(name[0], name[1]))
2085                 result = 1;
2086         ${cf_cv_main_return:-return}(result);
2087 }
2088 ],[cf_cv_func_mkstemp=yes
2089 ],[cf_cv_func_mkstemp=no
2090 ],[cf_cv_func_mkstemp=maybe])
2091 ])
2092 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
2093         AC_CHECK_FUNC(mkstemp)
2094 fi
2095 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
2096         AC_DEFINE(HAVE_MKSTEMP)
2097 fi
2098 ])dnl
2099 dnl ---------------------------------------------------------------------------
2100 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2101 dnl ----------
2102 dnl Write a debug message to config.log, along with the line number in the
2103 dnl configure script.
2104 AC_DEFUN([CF_MSG_LOG],[
2105 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2106 ])dnl
2107 dnl ---------------------------------------------------------------------------
2108 dnl CF_NCURSES_ADDON version: 4 updated: 2011/03/27 17:10:13
2109 dnl ----------------
2110 dnl Configure an ncurses add-on, built outside the ncurses tree.
2111 AC_DEFUN([CF_NCURSES_ADDON],[
2112
2113 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
2114
2115 AC_MSG_CHECKING(if you want wide-character code)
2116 AC_ARG_ENABLE(widec,
2117         [  --enable-widec          compile with wide-char/UTF-8 code],
2118         [with_widec=$enableval],
2119         [with_widec=no])
2120 AC_MSG_RESULT($with_widec)
2121 if test "$with_widec" = yes ; then
2122         CF_UTF8_LIB
2123         CF_NCURSES_CONFIG(ncursesw)
2124 else
2125         CF_NCURSES_CONFIG(ncurses)
2126 fi
2127
2128 if test "$NCURSES_CONFIG" != none ; then
2129
2130 cf_version=`$NCURSES_CONFIG --version`
2131
2132 NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2133 NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2134 NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2135
2136 # ABI version is not available from headers
2137 cf_cv_abi_version=`$NCURSES_CONFIG --abi-version`
2138
2139 else
2140
2141 for cf_name in MAJOR MINOR PATCH
2142 do
2143 cat >conftest.$ac_ext <<CF_EOF
2144 #include <${cf_cv_ncurses_header:-curses.h}>
2145 AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
2146 CF_EOF
2147         cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
2148         AC_TRY_EVAL(cf_try)
2149         if test -f conftest.out ; then
2150                 cf_result=`cat conftest.out | sed -e "s/^.*AUTOCONF_$cf_name[[  ]][[    ]]*//"`
2151                 eval NCURSES_$cf_name=\"$cf_result\"
2152                 # cat conftest.$ac_ext
2153                 # cat conftest.out
2154         fi
2155 done
2156
2157 cf_cv_abi_version=${NCURSES_MAJOR}
2158
2159 fi
2160
2161 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
2162
2163 dnl Show the computed version, for logging
2164 cf_cv_timestamp=`date`
2165
2166 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
2167
2168 dnl We need these values in the generated headers
2169 AC_SUBST(NCURSES_MAJOR)
2170 AC_SUBST(NCURSES_MINOR)
2171 AC_SUBST(NCURSES_PATCH)
2172
2173 dnl We need these values in the generated makefiles
2174 AC_SUBST(cf_cv_rel_version)
2175 AC_SUBST(cf_cv_abi_version)
2176
2177 dnl FIXME - not needed for Ada95
2178 AC_SUBST(cf_cv_builtin_bool)
2179 AC_SUBST(cf_cv_header_stdbool_h)
2180 AC_SUBST(cf_cv_type_of_bool)dnl
2181
2182 ])
2183 dnl ---------------------------------------------------------------------------
2184 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2185 dnl -------------------
2186 dnl Check if we can compile with ncurses' header file
2187 dnl $1 is the cache variable to set
2188 dnl $2 is the header-file to include
2189 dnl $3 is the root name (ncurses or ncursesw)
2190 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2191         AC_TRY_COMPILE([
2192 ]ifelse($3,ncursesw,[
2193 #define _XOPEN_SOURCE_EXTENDED
2194 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2195 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2196 ])[
2197 #include <$2>],[
2198 #ifdef NCURSES_VERSION
2199 ]ifelse($3,ncursesw,[
2200 #ifndef WACS_BSSB
2201         make an error
2202 #endif
2203 ])[
2204 printf("%s\n", NCURSES_VERSION);
2205 #else
2206 #ifdef __NCURSES_H
2207 printf("old\n");
2208 #else
2209         make an error
2210 #endif
2211 #endif
2212         ]
2213         ,[$1=$2]
2214         ,[$1=no])
2215 ])dnl
2216 dnl ---------------------------------------------------------------------------
2217 dnl CF_NCURSES_CONFIG version: 9 updated: 2011/11/26 15:42:05
2218 dnl -----------------
2219 dnl Tie together the configure-script macros for ncurses.
2220 dnl Prefer the "-config" script from ncurses 6.x, to simplify analysis.
2221 dnl Allow that to be overridden using the $NCURSES_CONFIG environment variable.
2222 dnl
2223 dnl $1 is the root library name (default: "ncurses")
2224 AC_DEFUN([CF_NCURSES_CONFIG],
2225 [
2226 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2227
2228 echo "Looking for ${cf_ncuconfig_root}-config"
2229
2230 CF_ACVERSION_CHECK(2.52,
2231         [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2232         [AC_PATH_PROGS(NCURSES_CONFIG, ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2233
2234 if test "$NCURSES_CONFIG" != none ; then
2235
2236 CPPFLAGS="$CPPFLAGS `$NCURSES_CONFIG --cflags`"
2237 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2238
2239 # even with config script, some packages use no-override for curses.h
2240 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2241
2242 dnl like CF_NCURSES_CPPFLAGS
2243 AC_DEFINE(NCURSES)
2244
2245 dnl like CF_NCURSES_LIBS
2246 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2247 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2248
2249 dnl like CF_NCURSES_VERSION
2250 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2251
2252 else
2253
2254 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2255 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2256
2257 fi
2258 ])dnl
2259 dnl ---------------------------------------------------------------------------
2260 dnl CF_NCURSES_CPPFLAGS version: 20 updated: 2010/11/20 17:02:38
2261 dnl -------------------
2262 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2263 dnl the CPPFLAGS variable so we can include its header.
2264 dnl
2265 dnl The header files may be installed as either curses.h, or ncurses.h (would
2266 dnl be obsolete, except that some packagers prefer this name to distinguish it
2267 dnl from a "native" curses implementation).  If not installed for overwrite,
2268 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2269 dnl /usr/include/ncurses), but someone may have installed overwriting the
2270 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2271 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2272 dnl the header.
2273 dnl
2274 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2275 dnl is already in the include-path, don't even bother with this, since we cannot
2276 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2277 dnl
2278 dnl The optional parameter gives the root name of the library, in case it is
2279 dnl not installed as the default curses library.  That is how the
2280 dnl wide-character version of ncurses is installed.
2281 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2282 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2283
2284 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2285 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2286
2287 test -n "$cf_cv_curses_dir" && \
2288 test "$cf_cv_curses_dir" != "no" && { \
2289   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2290 }
2291
2292 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2293         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2294         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2295         for cf_header in $cf_header_list
2296         do
2297                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2298                 test "$cf_cv_ncurses_h" != no && break
2299         done
2300 ])
2301
2302 CF_NCURSES_HEADER
2303 CF_TERM_HEADER
2304
2305 # some applications need this, but should check for NCURSES_VERSION
2306 AC_DEFINE(NCURSES)
2307
2308 CF_NCURSES_VERSION
2309 ])dnl
2310 dnl ---------------------------------------------------------------------------
2311 dnl CF_NCURSES_HEADER version: 2 updated: 2008/03/23 14:48:54
2312 dnl -----------------
2313 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2314 dnl variations of ncurses' installs.
2315 dnl
2316 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2317 AC_DEFUN([CF_NCURSES_HEADER],[
2318
2319 if test "$cf_cv_ncurses_h" != no ; then
2320         cf_cv_ncurses_header=$cf_cv_ncurses_h
2321 else
2322
2323 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2324         test -n "$verbose" && echo
2325         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2326         test -n "$verbose" && echo search path $cf_search
2327         cf_save2_CPPFLAGS="$CPPFLAGS"
2328         for cf_incdir in $cf_search
2329         do
2330                 CF_ADD_INCDIR($cf_incdir)
2331                 for cf_header in \
2332                         ncurses.h \
2333                         curses.h
2334                 do
2335                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2336                         if test "$cf_cv_ncurses_h2" != no ; then
2337                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2338                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2339                                 break
2340                         fi
2341                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2342                 done
2343                 CPPFLAGS="$cf_save2_CPPFLAGS"
2344                 test "$cf_cv_ncurses_h2" != no && break
2345         done
2346         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2347         ])
2348
2349         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2350         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2351         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2352                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2353         fi
2354         CF_ADD_INCDIR($cf_1st_incdir)
2355
2356 fi
2357
2358 # Set definitions to allow ifdef'ing for ncurses.h
2359
2360 case $cf_cv_ncurses_header in # (vi
2361 *ncurses.h)
2362         AC_DEFINE(HAVE_NCURSES_H)
2363         ;;
2364 esac
2365
2366 case $cf_cv_ncurses_header in # (vi
2367 ncurses/curses.h|ncurses/ncurses.h)
2368         AC_DEFINE(HAVE_NCURSES_NCURSES_H)
2369         ;;
2370 ncursesw/curses.h|ncursesw/ncurses.h)
2371         AC_DEFINE(HAVE_NCURSESW_NCURSES_H)
2372         ;;
2373 esac
2374
2375 ])dnl
2376 dnl ---------------------------------------------------------------------------
2377 dnl CF_NCURSES_LIBS version: 16 updated: 2010/11/20 17:02:38
2378 dnl ---------------
2379 dnl Look for the ncurses library.  This is a little complicated on Linux,
2380 dnl because it may be linked with the gpm (general purpose mouse) library.
2381 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2382 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2383 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2384 dnl and the linker will record a dependency.
2385 dnl
2386 dnl The optional parameter gives the root name of the library, in case it is
2387 dnl not installed as the default curses library.  That is how the
2388 dnl wide-character version of ncurses is installed.
2389 AC_DEFUN([CF_NCURSES_LIBS],
2390 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2391
2392 cf_nculib_root=ifelse($1,,ncurses,$1)
2393         # This works, except for the special case where we find gpm, but
2394         # ncurses is in a nonstandard location via $LIBS, and we really want
2395         # to link gpm.
2396 cf_ncurses_LIBS=""
2397 cf_ncurses_SAVE="$LIBS"
2398 AC_CHECK_LIB(gpm,Gpm_Open,
2399         [AC_CHECK_LIB(gpm,initscr,
2400                 [LIBS="$cf_ncurses_SAVE"],
2401                 [cf_ncurses_LIBS="-lgpm"])])
2402
2403 case $host_os in #(vi
2404 freebsd*)
2405         # This is only necessary if you are linking against an obsolete
2406         # version of ncurses (but it should do no harm, since it's static).
2407         if test "$cf_nculib_root" = ncurses ; then
2408                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2409         fi
2410         ;;
2411 esac
2412
2413 CF_ADD_LIBS($cf_ncurses_LIBS)
2414
2415 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2416 then
2417         CF_ADD_LIBS(-l$cf_nculib_root)
2418 else
2419         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2420                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2421                 [initscr()],
2422                 initscr)
2423 fi
2424
2425 if test -n "$cf_ncurses_LIBS" ; then
2426         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2427         cf_ncurses_SAVE="$LIBS"
2428         for p in $cf_ncurses_LIBS ; do
2429                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2430                 if test "$q" != "$LIBS" ; then
2431                         LIBS="$q"
2432                 fi
2433         done
2434         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2435                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2436                 [AC_MSG_RESULT(yes)],
2437                 [AC_MSG_RESULT(no)
2438                  LIBS="$cf_ncurses_SAVE"])
2439 fi
2440
2441 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2442 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2443 ])dnl
2444 dnl ---------------------------------------------------------------------------
2445 dnl CF_NCURSES_VERSION version: 13 updated: 2010/10/23 15:54:49
2446 dnl ------------------
2447 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2448 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2449 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2450 AC_DEFUN([CF_NCURSES_VERSION],
2451 [
2452 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2453 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2454         cf_cv_ncurses_version=no
2455         cf_tempfile=out$$
2456         rm -f $cf_tempfile
2457         AC_TRY_RUN([
2458 #include <${cf_cv_ncurses_header:-curses.h}>
2459 #include <stdio.h>
2460 int main()
2461 {
2462         FILE *fp = fopen("$cf_tempfile", "w");
2463 #ifdef NCURSES_VERSION
2464 # ifdef NCURSES_VERSION_PATCH
2465         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2466 # else
2467         fprintf(fp, "%s\n", NCURSES_VERSION);
2468 # endif
2469 #else
2470 # ifdef __NCURSES_H
2471         fprintf(fp, "old\n");
2472 # else
2473         make an error
2474 # endif
2475 #endif
2476         ${cf_cv_main_return:-return}(0);
2477 }],[
2478         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2479
2480         # This will not work if the preprocessor splits the line after the
2481         # Autoconf token.  The 'unproto' program does that.
2482         cat > conftest.$ac_ext <<EOF
2483 #include <${cf_cv_ncurses_header:-curses.h}>
2484 #undef Autoconf
2485 #ifdef NCURSES_VERSION
2486 Autoconf NCURSES_VERSION
2487 #else
2488 #ifdef __NCURSES_H
2489 Autoconf "old"
2490 #endif
2491 ;
2492 #endif
2493 EOF
2494         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2495         AC_TRY_EVAL(cf_try)
2496         if test -f conftest.out ; then
2497                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2498                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2499                 rm -f conftest.out
2500         fi
2501 ])
2502         rm -f $cf_tempfile
2503 ])
2504 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES)
2505 ])dnl
2506 dnl ---------------------------------------------------------------------------
2507 dnl CF_NO_LEAKS_OPTION version: 4 updated: 2006/12/16 14:24:05
2508 dnl ------------------
2509 dnl see CF_WITH_NO_LEAKS
2510 AC_DEFUN([CF_NO_LEAKS_OPTION],[
2511 AC_MSG_CHECKING(if you want to use $1 for testing)
2512 AC_ARG_WITH($1,
2513         [$2],
2514         [AC_DEFINE($3)ifelse([$4],,[
2515          $4
2516 ])
2517         : ${with_cflags:=-g}
2518         : ${with_no_leaks:=yes}
2519          with_$1=yes],
2520         [with_$1=])
2521 AC_MSG_RESULT(${with_$1:-no})
2522
2523 case .$with_cflags in #(vi
2524 .*-g*)
2525         case .$CFLAGS in #(vi
2526         .*-g*) #(vi
2527                 ;;
2528         *)
2529                 CF_ADD_CFLAGS([-g])
2530                 ;;
2531         esac
2532         ;;
2533 esac
2534 ])dnl
2535 dnl ---------------------------------------------------------------------------
2536 dnl CF_NUMBER_SYNTAX version: 1 updated: 2003/09/20 18:12:49
2537 dnl ----------------
2538 dnl Check if the given variable is a number.  If not, report an error.
2539 dnl $1 is the variable
2540 dnl $2 is the message
2541 AC_DEFUN([CF_NUMBER_SYNTAX],[
2542 if test -n "$1" ; then
2543   case $1 in #(vi
2544   [[0-9]]*) #(vi
2545         ;;
2546   *)
2547         AC_MSG_ERROR($2 is not a number: $1)
2548         ;;
2549   esac
2550 else
2551   AC_MSG_ERROR($2 value is empty)
2552 fi
2553 ])dnl
2554 dnl ---------------------------------------------------------------------------
2555 dnl CF_OBJ_SUBDIR version: 4 updated: 2002/02/23 20:38:31
2556 dnl -------------
2557 dnl Compute the object-directory name from the given model name
2558 AC_DEFUN([CF_OBJ_SUBDIR],
2559 [
2560         case $1 in
2561         libtool) $2='obj_lo'  ;;
2562         normal)  $2='objects' ;;
2563         debug)   $2='obj_g' ;;
2564         profile) $2='obj_p' ;;
2565         shared)
2566                 case $cf_cv_system_name in #(vi
2567                 cygwin) #(vi
2568                         $2='objects' ;;
2569                 *)
2570                         $2='obj_s' ;;
2571                 esac
2572         esac
2573 ])dnl
2574 dnl ---------------------------------------------------------------------------
2575 dnl CF_PATHSEP version: 5 updated: 2010/05/26 05:38:42
2576 dnl ----------
2577 dnl Provide a value for the $PATH and similar separator
2578 AC_DEFUN([CF_PATHSEP],
2579 [
2580         case $cf_cv_system_name in
2581         os2*)   PATH_SEPARATOR=';'  ;;
2582         *)      PATH_SEPARATOR=':'  ;;
2583         esac
2584 ifelse([$1],,,[$1=$PATH_SEPARATOR])
2585         AC_SUBST(PATH_SEPARATOR)
2586 ])dnl
2587 dnl ---------------------------------------------------------------------------
2588 dnl CF_PATH_SYNTAX version: 13 updated: 2010/05/26 05:38:42
2589 dnl --------------
2590 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2591 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2592 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2593 dnl delayed evaluation of those symbols.
2594 AC_DEFUN([CF_PATH_SYNTAX],[
2595 if test "x$prefix" != xNONE; then
2596   cf_path_syntax="$prefix"
2597 else
2598   cf_path_syntax="$ac_default_prefix"
2599 fi
2600
2601 case ".[$]$1" in #(vi
2602 .\[$]\(*\)*|.\'*\'*) #(vi
2603   ;;
2604 ..|./*|.\\*) #(vi
2605   ;;
2606 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
2607   ;;
2608 .\[$]{*prefix}*) #(vi
2609   eval $1="[$]$1"
2610   case ".[$]$1" in #(vi
2611   .NONE/*)
2612     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2613     ;;
2614   esac
2615   ;; #(vi
2616 .no|.NONE/*)
2617   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2618   ;;
2619 *)
2620   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2621   ;;
2622 esac
2623 ])dnl
2624 dnl ---------------------------------------------------------------------------
2625 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
2626 dnl -------------
2627 dnl Check for the package-config program, unless disabled by command-line.
2628 AC_DEFUN([CF_PKG_CONFIG],
2629 [
2630 AC_MSG_CHECKING(if you want to use pkg-config)
2631 AC_ARG_WITH(pkg-config,
2632         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2633         [cf_pkg_config=$withval],
2634         [cf_pkg_config=yes])
2635 AC_MSG_RESULT($cf_pkg_config)
2636
2637 case $cf_pkg_config in #(vi
2638 no) #(vi
2639         PKG_CONFIG=none
2640         ;;
2641 yes) #(vi
2642         CF_ACVERSION_CHECK(2.52,
2643                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2644                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2645         ;;
2646 *)
2647         PKG_CONFIG=$withval
2648         ;;
2649 esac
2650
2651 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2652 if test "$PKG_CONFIG" != none ; then
2653         CF_PATH_SYNTAX(PKG_CONFIG)
2654 fi
2655
2656 AC_SUBST(PKG_CONFIG)
2657 ])dnl
2658 dnl ---------------------------------------------------------------------------
2659 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
2660 dnl -----------------
2661 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2662 dnl
2663 dnl     POSIX.1-1990                            _POSIX_SOURCE
2664 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2665 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2666 dnl             Bindings Option
2667 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2668 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2669 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2670 dnl
2671 dnl Parameters:
2672 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2673 AC_DEFUN([CF_POSIX_C_SOURCE],
2674 [
2675 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2676
2677 cf_save_CFLAGS="$CFLAGS"
2678 cf_save_CPPFLAGS="$CPPFLAGS"
2679
2680 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2681 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2682
2683 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2684         CF_MSG_LOG(if the symbol is already defined go no further)
2685         AC_TRY_COMPILE([#include <sys/types.h>],[
2686 #ifndef _POSIX_C_SOURCE
2687 make an error
2688 #endif],
2689         [cf_cv_posix_c_source=no],
2690         [cf_want_posix_source=no
2691          case .$cf_POSIX_C_SOURCE in #(vi
2692          .[[12]]??*) #(vi
2693                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2694                 ;;
2695          .2) #(vi
2696                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2697                 cf_want_posix_source=yes
2698                 ;;
2699          .*)
2700                 cf_want_posix_source=yes
2701                 ;;
2702          esac
2703          if test "$cf_want_posix_source" = yes ; then
2704                 AC_TRY_COMPILE([#include <sys/types.h>],[
2705 #ifdef _POSIX_SOURCE
2706 make an error
2707 #endif],[],
2708                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2709          fi
2710          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2711          CFLAGS="$cf_trim_CFLAGS"
2712          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
2713          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2714          AC_TRY_COMPILE([#include <sys/types.h>],[
2715 #ifndef _POSIX_C_SOURCE
2716 make an error
2717 #endif],,
2718          [cf_cv_posix_c_source=no])
2719          CFLAGS="$cf_save_CFLAGS"
2720          CPPFLAGS="$cf_save_CPPFLAGS"
2721         ])
2722 ])
2723
2724 if test "$cf_cv_posix_c_source" != no ; then
2725         CFLAGS="$cf_trim_CFLAGS"
2726         CPPFLAGS="$cf_trim_CPPFLAGS"
2727         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2728 fi
2729
2730 ])dnl
2731 dnl ---------------------------------------------------------------------------
2732 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
2733 dnl ----------
2734 dnl Check for archiver "ar".
2735 AC_DEFUN([CF_PROG_AR],[
2736 AC_CHECK_TOOL(AR, ar, ar)
2737 ])
2738 dnl ---------------------------------------------------------------------------
2739 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
2740 dnl -----------
2741 dnl Check for awk, ensure that the check found something.
2742 AC_DEFUN([CF_PROG_AWK],
2743 [
2744 AC_PROG_AWK
2745 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
2746 ])dnl
2747 dnl ---------------------------------------------------------------------------
2748 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
2749 dnl --------------
2750 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
2751 dnl the output file can be renamed, and allows for a shell variable that can
2752 dnl be used later.  The parameter is either CC or CXX.  The result is the
2753 dnl cache variable:
2754 dnl     $cf_cv_prog_CC_c_o
2755 dnl     $cf_cv_prog_CXX_c_o
2756 AC_DEFUN([CF_PROG_CC_C_O],
2757 [AC_REQUIRE([AC_PROG_CC])dnl
2758 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
2759 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
2760 [
2761 cat > conftest.$ac_ext <<CF_EOF
2762 #include <stdio.h>
2763 int main()
2764 {
2765         ${cf_cv_main_return:-return}(0);
2766 }
2767 CF_EOF
2768 # We do the test twice because some compilers refuse to overwrite an
2769 # existing .o file with -o, though they will create one.
2770 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
2771 if AC_TRY_EVAL(ac_try) &&
2772   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
2773 then
2774   eval cf_cv_prog_$1_c_o=yes
2775 else
2776   eval cf_cv_prog_$1_c_o=no
2777 fi
2778 rm -rf conftest*
2779 ])dnl
2780 if test $cf_cv_prog_$1_c_o = yes; then
2781   AC_MSG_RESULT([yes])
2782 else
2783   AC_MSG_RESULT([no])
2784 fi
2785 ])dnl
2786 dnl ---------------------------------------------------------------------------
2787 dnl CF_PROG_EGREP version: 1 updated: 2006/09/16 11:40:59
2788 dnl -------------
2789 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
2790 dnl This macro adds a check to ensure the script found something.
2791 AC_DEFUN([CF_PROG_EGREP],
2792 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
2793    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
2794     then ac_cv_prog_egrep='grep -E'
2795     else ac_cv_prog_egrep='egrep'
2796     fi])
2797  EGREP=$ac_cv_prog_egrep
2798  AC_SUBST([EGREP])
2799 test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
2800 ])dnl
2801 dnl ---------------------------------------------------------------------------
2802 dnl CF_PROG_EXT version: 10 updated: 2004/01/03 19:28:18
2803 dnl -----------
2804 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
2805 AC_DEFUN([CF_PROG_EXT],
2806 [
2807 AC_REQUIRE([CF_CHECK_CACHE])
2808 case $cf_cv_system_name in
2809 os2*)
2810     CFLAGS="$CFLAGS -Zmt"
2811     CPPFLAGS="$CPPFLAGS -D__ST_MT_ERRNO__"
2812     CXXFLAGS="$CXXFLAGS -Zmt"
2813     # autoconf's macro sets -Zexe and suffix both, which conflict:w
2814     LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
2815     ac_cv_exeext=.exe
2816     ;;
2817 esac
2818
2819 AC_EXEEXT
2820 AC_OBJEXT
2821
2822 PROG_EXT="$EXEEXT"
2823 AC_SUBST(PROG_EXT)
2824 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT")
2825 ])dnl
2826 dnl ---------------------------------------------------------------------------
2827 dnl CF_PROG_GNAT version: 2 updated: 2011/10/22 14:01:47
2828 dnl ------------
2829 dnl Check for gnatmake, ensure that it is complete.
2830 AC_DEFUN([CF_PROG_GNAT],[
2831 cf_ada_make=gnatmake
2832 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
2833 if test "$ac_cv_prog_gnat_exists" = no; then
2834    cf_ada_make=
2835    cf_cv_prog_gnat_correct=no
2836 else
2837    CF_GNAT_VERSION
2838    AC_CHECK_PROG(M4_exists, m4, yes, no)
2839    if test "$ac_cv_prog_M4_exists" = no; then
2840       cf_cv_prog_gnat_correct=no
2841       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
2842    fi
2843    if test "$cf_cv_prog_gnat_correct" = yes; then
2844       AC_MSG_CHECKING(if GNAT works)
2845       CF_GNAT_TRY_RUN([procedure conftest;],
2846 [with Text_IO;
2847 with GNAT.OS_Lib;
2848 procedure conftest is
2849 begin
2850    Text_IO.Put ("Hello World");
2851    Text_IO.New_Line;
2852    GNAT.OS_Lib.OS_Exit (0);
2853 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
2854       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
2855    fi
2856 fi
2857
2858 AC_SUBST(cf_ada_make)
2859 ])dnl
2860 dnl ---------------------------------------------------------------------------
2861 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
2862 dnl ------------
2863 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
2864 dnl option if it is supported.
2865 AC_DEFUN([CF_PROG_LN_S],[
2866 AC_PROG_LN_S
2867 AC_MSG_CHECKING(if $LN_S -f options work)
2868
2869 rm -f conf$$.src conf$$dst
2870 echo >conf$$.dst
2871 echo first >conf$$.src
2872 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
2873         cf_prog_ln_sf=yes
2874 else
2875         cf_prog_ln_sf=no
2876 fi
2877 rm -f conf$$.dst conf$$src
2878 AC_MSG_RESULT($cf_prog_ln_sf)
2879
2880 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
2881 ])dnl
2882 dnl ---------------------------------------------------------------------------
2883 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
2884 dnl ----------------
2885 dnl Remove all -U and -D options that refer to the given symbol from a list
2886 dnl of C compiler options.  This works around the problem that not all
2887 dnl compilers process -U and -D options from left-to-right, so a -U option
2888 dnl cannot be used to cancel the effect of a preceding -D option.
2889 dnl
2890 dnl $1 = target (which could be the same as the source variable)
2891 dnl $2 = source (including '$')
2892 dnl $3 = symbol to remove
2893 define([CF_REMOVE_DEFINE],
2894 [
2895 $1=`echo "$2" | \
2896         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
2897                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
2898 ])dnl
2899 dnl ---------------------------------------------------------------------------
2900 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
2901 dnl -------------
2902 dnl Remove the given library from the symbol
2903 dnl
2904 dnl $1 = target (which could be the same as the source variable)
2905 dnl $2 = source (including '$')
2906 dnl $3 = library to remove
2907 define([CF_REMOVE_LIB],
2908 [
2909 # remove $3 library from $2
2910 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
2911 ])dnl
2912 dnl ---------------------------------------------------------------------------
2913 dnl CF_SHARED_OPTS version: 69 updated: 2011/07/30 19:31:39
2914 dnl --------------
2915 dnl --------------
2916 dnl Attempt to determine the appropriate CC/LD options for creating a shared
2917 dnl library.
2918 dnl
2919 dnl Note: ${LOCAL_LDFLAGS} is used to link executables that will run within the
2920 dnl build-tree, i.e., by making use of the libraries that are compiled in ../lib
2921 dnl We avoid compiling-in a ../lib path for the shared library since that can
2922 dnl lead to unexpected results at runtime.
2923 dnl ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared libraries
2924 dnl are compiled in ../../lib
2925 dnl
2926 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
2927 dnl to install symbolic links to the rel/abi versions of shared libraries.
2928 dnl
2929 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
2930 dnl version when making symbolic links.
2931 dnl
2932 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
2933 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
2934 dnl (ex: libncurses.so.<ver>).
2935 dnl
2936 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
2937 AC_DEFUN([CF_SHARED_OPTS],
2938 [
2939         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
2940         AC_REQUIRE([CF_LD_RPATH_OPT])
2941         LOCAL_LDFLAGS=
2942         LOCAL_LDFLAGS2=
2943         LD_SHARED_OPTS=
2944         INSTALL_LIB="-m 644"
2945
2946         cf_cv_do_symlinks=no
2947         cf_ld_rpath_opt=
2948         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
2949
2950         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
2951         AC_ARG_WITH(shlib-version,
2952         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
2953         [test -z "$withval" && withval=auto
2954         case $withval in #(vi
2955         yes) #(vi
2956                 cf_cv_shlib_version=auto
2957                 ;;
2958         rel|abi|auto|no) #(vi
2959                 cf_cv_shlib_version=$withval
2960                 ;;
2961         *)
2962                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
2963                 ;;
2964         esac
2965         ],[cf_cv_shlib_version=auto])
2966         AC_MSG_RESULT($cf_cv_shlib_version)
2967
2968         cf_cv_rm_so_locs=no
2969
2970         # Some less-capable ports of gcc support only -fpic
2971         CC_SHARED_OPTS=
2972         if test "$GCC" = yes
2973         then
2974                 AC_MSG_CHECKING(which $CC option to use)
2975                 cf_save_CFLAGS="$CFLAGS"
2976                 for CC_SHARED_OPTS in -fPIC -fpic ''
2977                 do
2978                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
2979                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
2980                 done
2981                 AC_MSG_RESULT($CC_SHARED_OPTS)
2982                 CFLAGS="$cf_save_CFLAGS"
2983         fi
2984
2985         cf_cv_shlib_version_infix=no
2986
2987         case $cf_cv_system_name in #(vi
2988         aix4.[3-9]*|aix[[5-7]]*) #(vi
2989                 if test "$GCC" = yes; then
2990                         CC_SHARED_OPTS=
2991                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
2992                 else
2993                         # CC_SHARED_OPTS='-qpic=large -G'
2994                         # perhaps "-bM:SRE -bnoentry -bexpall"
2995                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
2996                 fi
2997                 ;;
2998         beos*) #(vi
2999                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
3000                 ;;
3001         cygwin*) #(vi
3002                 CC_SHARED_OPTS=
3003                 MK_SHARED_LIB='sh ../mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3004                 cf_cv_shlib_version=cygdll
3005                 cf_cv_shlib_version_infix=cygdll
3006                 cat >mk_shared_lib.sh <<-CF_EOF
3007                 #!/bin/sh
3008                 SHARED_LIB=\[$]1
3009                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3010                 shift
3011                 cat <<-EOF
3012                 Linking shared library
3013                 ** SHARED_LIB \[$]SHARED_LIB
3014                 ** IMPORT_LIB \[$]IMPORT_LIB
3015 EOF
3016                 exec \[$]* -shared -Wl,--out-implib=../lib/\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o ../lib/\[$]{SHARED_LIB}
3017 CF_EOF
3018                 chmod +x mk_shared_lib.sh
3019                 ;;
3020         darwin*) #(vi
3021                 EXTRA_CFLAGS="-no-cpp-precomp"
3022                 CC_SHARED_OPTS="-dynamic"
3023                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
3024                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
3025                 cf_cv_shlib_version_infix=yes
3026                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
3027                         cf_save_LDFLAGS=$LDFLAGS
3028                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3029                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
3030                                 LDFLAGS=$cf_save_LDFLAGS])
3031                 if test $cf_cv_ldflags_search_paths_first = yes; then
3032                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3033                 fi
3034                 ;;
3035         hpux*) #(vi
3036                 # (tested with gcc 2.7.2 -- I don't have c89)
3037                 if test "$GCC" = yes; then
3038                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
3039                 else
3040                         CC_SHARED_OPTS='+Z'
3041                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
3042                 fi
3043                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
3044                 # HP-UX shared libraries must be executable, and should be
3045                 # readonly to exploit a quirk in the memory manager.
3046                 INSTALL_LIB="-m 555"
3047                 ;;
3048         interix*)
3049                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3050                 if test "$cf_cv_shlib_version" = rel; then
3051                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
3052                 else
3053                         cf_shared_soname='`basename $@`'
3054                 fi
3055                 CC_SHARED_OPTS=
3056                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
3057                 ;;
3058         irix*) #(vi
3059                 if test "$cf_cv_enable_rpath" = yes ; then
3060                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3061                 fi
3062                 # tested with IRIX 5.2 and 'cc'.
3063                 if test "$GCC" != yes; then
3064                         CC_SHARED_OPTS='-KPIC'
3065                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
3066                 else
3067                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
3068                 fi
3069                 cf_cv_rm_so_locs=yes
3070                 ;;
3071         linux*|gnu*|k*bsd*-gnu) #(vi
3072                 if test "$DFT_LWR_MODEL" = "shared" ; then
3073                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3074                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3075                 fi
3076                 if test "$cf_cv_enable_rpath" = yes ; then
3077                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3078                 fi
3079                 CF_SHARED_SONAME
3080                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3081                 ;;
3082         openbsd[[2-9]].*|mirbsd*) #(vi
3083                 if test "$DFT_LWR_MODEL" = "shared" ; then
3084                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3085                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3086                 fi
3087                 if test "$cf_cv_enable_rpath" = yes ; then
3088                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3089                 fi
3090                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3091                 CF_SHARED_SONAME
3092                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3093                 ;;
3094         nto-qnx*|openbsd*|freebsd[[12]].*) #(vi
3095                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3096                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
3097                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3098                 ;;
3099         dragonfly*|freebsd*) #(vi
3100                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3101                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3102                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3103                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
3104                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3105                 fi
3106                 CF_SHARED_SONAME
3107                 MK_SHARED_LIB='${LD} -shared -Bshareable -soname=`basename $[@]` -o $[@]'
3108                 ;;
3109         netbsd*) #(vi
3110                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3111                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3112                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3113                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3114                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3115                         if test "$cf_cv_shlib_version" = auto; then
3116                         if test -f /usr/libexec/ld.elf_so; then
3117                                 cf_cv_shlib_version=abi
3118                         else
3119                                 cf_cv_shlib_version=rel
3120                         fi
3121                         fi
3122                         CF_SHARED_SONAME
3123                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
3124                 else
3125                         MK_SHARED_LIB='${LD} -shared -Bshareable -o $[@]'
3126                 fi
3127                 ;;
3128         osf*|mls+*) #(vi
3129                 # tested with OSF/1 V3.2 and 'cc'
3130                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
3131                 # link with shared libs).
3132                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
3133                 case $host_os in #(vi
3134                 osf4*)
3135                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
3136                         ;;
3137                 esac
3138                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
3139                 if test "$DFT_LWR_MODEL" = "shared" ; then
3140                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3141                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3142                 fi
3143                 cf_cv_rm_so_locs=yes
3144                 ;;
3145         sco3.2v5*)  # (also uw2* and UW7: hops 13-Apr-98
3146                 # tested with osr5.0.5
3147                 if test "$GCC" != yes; then
3148                         CC_SHARED_OPTS='-belf -KPIC'
3149                 fi
3150                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
3151                 if test "$cf_cv_enable_rpath" = yes ; then
3152                         # only way is to set LD_RUN_PATH but no switch for it
3153                         RUN_PATH=$libdir
3154                 fi
3155                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3156                 LINK_PROGS='LD_RUN_PATH=${libdir}'
3157                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
3158                 ;;
3159         sunos4*) #(vi
3160                 # tested with SunOS 4.1.1 and gcc 2.7.0
3161                 if test "$GCC" != yes; then
3162                         CC_SHARED_OPTS='-KPIC'
3163                 fi
3164                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
3165                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3166                 ;;
3167         solaris2*) #(vi
3168                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
3169                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
3170                 if test "$DFT_LWR_MODEL" = "shared" ; then
3171                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
3172                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3173                 fi
3174                 if test "$cf_cv_enable_rpath" = yes ; then
3175                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
3176                 fi
3177                 CF_SHARED_SONAME
3178                 if test "$GCC" != yes; then
3179                         cf_save_CFLAGS="$CFLAGS"
3180                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
3181                         do
3182                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
3183                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
3184                         done
3185                         CFLAGS="$cf_save_CFLAGS"
3186                         CC_SHARED_OPTS=$cf_shared_opts
3187                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3188                 else
3189                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3190                 fi
3191                 ;;
3192         sysv5uw7*|unix_sv*) #(vi
3193                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
3194                 if test "$GCC" != yes; then
3195                         CC_SHARED_OPTS='-KPIC'
3196                 fi
3197                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
3198                 ;;
3199         *)
3200                 CC_SHARED_OPTS='unknown'
3201                 MK_SHARED_LIB='echo unknown'
3202                 ;;
3203         esac
3204
3205         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
3206         case "$cf_cv_shlib_version" in #(vi
3207         rel|abi)
3208                 case "$MK_SHARED_LIB" in #(vi
3209                 *'-o $[@]') #(vi
3210                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
3211                         ;;
3212                 *)
3213                         AC_MSG_WARN(ignored --with-shlib-version)
3214                         ;;
3215                 esac
3216                 ;;
3217         esac
3218
3219         # RPATH_LIST is a colon-separated list of directories
3220         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
3221         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
3222
3223         AC_SUBST(CC_SHARED_OPTS)
3224         AC_SUBST(LD_RPATH_OPT)
3225         AC_SUBST(LD_SHARED_OPTS)
3226         AC_SUBST(MK_SHARED_LIB)
3227         AC_SUBST(LINK_PROGS)
3228         AC_SUBST(LINK_TESTS)
3229         AC_SUBST(EXTRA_LDFLAGS)
3230         AC_SUBST(LOCAL_LDFLAGS)
3231         AC_SUBST(LOCAL_LDFLAGS2)
3232         AC_SUBST(INSTALL_LIB)
3233         AC_SUBST(RPATH_LIST)
3234 ])dnl
3235 dnl ---------------------------------------------------------------------------
3236 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
3237 dnl ----------------
3238 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
3239 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
3240 dnl option.
3241 dnl
3242 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
3243 dnl If missing, use "rel".
3244 define([CF_SHARED_SONAME],
3245 [
3246         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
3247         if test "$cf_cv_shlib_version" = rel; then
3248                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
3249         else
3250                 cf_cv_shared_soname='`basename $[@]`'
3251         fi
3252 ])
3253 dnl ---------------------------------------------------------------------------
3254 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
3255 dnl --------------
3256 dnl     Remove "-g" option from the compiler options
3257 AC_DEFUN([CF_STRIP_G_OPT],
3258 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
3259 dnl ---------------------------------------------------------------------------
3260 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
3261 dnl --------------
3262 dnl Construct a search-list for a nonstandard header/lib-file
3263 dnl     $1 = the variable to return as result
3264 dnl     $2 = the package name
3265 dnl     $3 = the subdirectory, e.g., bin, include or lib
3266 AC_DEFUN([CF_SUBDIR_PATH],
3267 [
3268 $1=
3269
3270 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
3271 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
3272 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
3273 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
3274 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
3275 ])dnl
3276 dnl ---------------------------------------------------------------------------
3277 dnl CF_SUBST version: 4 updated: 2006/06/17 12:33:03
3278 dnl --------
3279 dnl     Shorthand macro for substituting things that the user may override
3280 dnl     with an environment variable.
3281 dnl
3282 dnl     $1 = long/descriptive name
3283 dnl     $2 = environment variable
3284 dnl     $3 = default value
3285 AC_DEFUN([CF_SUBST],
3286 [AC_CACHE_VAL(cf_cv_subst_$2,[
3287 AC_MSG_CHECKING(for $1 (symbol $2))
3288 CF_SUBST_IF([-z "[$]$2"], [$2], [$3])
3289 cf_cv_subst_$2=[$]$2
3290 AC_MSG_RESULT([$]$2)
3291 ])
3292 ])dnl
3293 dnl ---------------------------------------------------------------------------
3294 dnl CF_TERM_HEADER version: 2 updated: 2010/10/23 15:54:49
3295 dnl --------------
3296 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
3297 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
3298 dnl but some packagers change this, breaking various applications.
3299 AC_DEFUN([CF_TERM_HEADER],[
3300 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
3301 case ${cf_cv_ncurses_header} in #(vi
3302 */ncurses.h|*/ncursesw.h) #(vi
3303         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
3304         ;;
3305 *)
3306         cf_term_header=term.h
3307         ;;
3308 esac
3309
3310 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
3311 do
3312 AC_TRY_COMPILE([#include <stdio.h>
3313 #include <${cf_cv_ncurses_header:-curses.h}>
3314 #include <$cf_test>
3315 ],[int x = auto_left_margin],[
3316         cf_cv_term_header="$cf_test"],[
3317         cf_cv_term_header=unknown
3318         ])
3319         test "$cf_cv_term_header" != unknown && break
3320 done
3321 ])
3322
3323 # Set definitions to allow ifdef'ing to accommodate subdirectories
3324
3325 case $cf_cv_term_header in # (vi
3326 *term.h)
3327         AC_DEFINE(HAVE_TERM_H)
3328         ;;
3329 esac
3330
3331 case $cf_cv_term_header in # (vi
3332 ncurses/term.h) #(vi
3333         AC_DEFINE(HAVE_NCURSES_TERM_H)
3334         ;;
3335 ncursesw/term.h)
3336         AC_DEFINE(HAVE_NCURSESW_TERM_H)
3337         ;;
3338 esac
3339 ])dnl
3340 dnl ---------------------------------------------------------------------------
3341 dnl CF_TOP_BUILDDIR version: 1 updated: 2006/10/15 16:33:23
3342 dnl ---------------
3343 dnl Define a top_builddir symbol, for applications that need an absolute path.
3344 AC_DEFUN([CF_TOP_BUILDDIR],
3345 [
3346 top_builddir=`pwd`
3347 AC_SUBST(top_builddir)
3348 ])dnl
3349 dnl ---------------------------------------------------------------------------
3350 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
3351 dnl -------------------
3352 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
3353 dnl can define it successfully.
3354 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
3355 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
3356         AC_TRY_COMPILE([
3357 #include <stdlib.h>
3358 #include <string.h>
3359 #include <sys/types.h>
3360 ],[
3361 #ifndef _XOPEN_SOURCE
3362 make an error
3363 #endif],
3364         [cf_cv_xopen_source=no],
3365         [cf_save="$CPPFLAGS"
3366          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3367          AC_TRY_COMPILE([
3368 #include <stdlib.h>
3369 #include <string.h>
3370 #include <sys/types.h>
3371 ],[
3372 #ifdef _XOPEN_SOURCE
3373 make an error
3374 #endif],
3375         [cf_cv_xopen_source=no],
3376         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
3377         CPPFLAGS="$cf_save"
3378         ])
3379 ])
3380
3381 if test "$cf_cv_xopen_source" != no ; then
3382         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
3383         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
3384         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
3385         CF_ADD_CFLAGS($cf_temp_xopen_source)
3386 fi
3387 ])
3388 dnl ---------------------------------------------------------------------------
3389 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
3390 dnl --------
3391 dnl Make an uppercase version of a variable
3392 dnl $1=uppercase($2)
3393 AC_DEFUN([CF_UPPER],
3394 [
3395 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
3396 ])dnl
3397 dnl ---------------------------------------------------------------------------
3398 dnl CF_UTF8_LIB version: 7 updated: 2010/06/20 09:24:28
3399 dnl -----------
3400 dnl Check for multibyte support, and if not found, utf8 compatibility library
3401 AC_DEFUN([CF_UTF8_LIB],
3402 [
3403 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
3404         cf_save_LIBS="$LIBS"
3405         AC_TRY_LINK([
3406 #include <stdlib.h>],[putwc(0,0);],
3407         [cf_cv_utf8_lib=yes],
3408         [CF_FIND_LINKAGE([
3409 #include <libutf8.h>],[putwc(0,0);],utf8,
3410                 [cf_cv_utf8_lib=add-on],
3411                 [cf_cv_utf8_lib=no])
3412 ])])
3413
3414 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
3415 # ncurses/ncursesw:
3416 if test "$cf_cv_utf8_lib" = "add-on" ; then
3417         AC_DEFINE(HAVE_LIBUTF8_H)
3418         CF_ADD_INCDIR($cf_cv_header_path_utf8)
3419         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
3420         CF_ADD_LIBS($cf_cv_library_file_utf8)
3421 fi
3422 ])dnl
3423 dnl ---------------------------------------------------------------------------
3424 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
3425 dnl ----------
3426 dnl Use AC_VERBOSE w/o the warnings
3427 AC_DEFUN([CF_VERBOSE],
3428 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
3429 CF_MSG_LOG([$1])
3430 ])dnl
3431 dnl ---------------------------------------------------------------------------
3432 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
3433 dnl ---------------
3434 dnl Check for compiler-support for weak symbols.
3435 dnl This works with "recent" gcc.
3436 AC_DEFUN([CF_WEAK_SYMBOLS],[
3437 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
3438
3439 AC_TRY_COMPILE([
3440 #include <stdio.h>],
3441 [
3442 #if defined(__GNUC__)
3443 #  if defined __USE_ISOC99
3444 #    define _cat_pragma(exp)    _Pragma(#exp)
3445 #    define _weak_pragma(exp)   _cat_pragma(weak name)
3446 #  else
3447 #    define _weak_pragma(exp)
3448 #  endif
3449 #  define _declare(name)        __extension__ extern __typeof__(name) name
3450 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
3451 #endif
3452
3453 weak_symbol(fopen);
3454 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
3455 ])
3456 ])dnl
3457 dnl ---------------------------------------------------------------------------
3458 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
3459 dnl --------------------
3460 dnl Command-line option to specify the Ada95 compiler.
3461 AC_DEFUN([CF_WITH_ADA_COMPILER],[
3462 AC_MSG_CHECKING(for ada-compiler)
3463 AC_ARG_WITH(ada-compiler,
3464         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
3465         [cf_ada_compiler=$withval],
3466         [cf_ada_compiler=gnatmake])
3467 AC_SUBST(cf_ada_compiler)
3468 AC_MSG_RESULT($cf_ada_compiler)
3469 ])dnl
3470 dnl ---------------------------------------------------------------------------
3471 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
3472 dnl -------------------
3473 dnl Command-line option to specify where Ada includes will install.
3474 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
3475 AC_MSG_CHECKING(for ada-include)
3476 CF_WITH_PATH(ada-include,
3477    [  --with-ada-include=DIR  Ada includes are in DIR],
3478    ADA_INCLUDE,
3479    PREFIX/share/ada/adainclude,
3480    [$]prefix/share/ada/adainclude)
3481 AC_SUBST(ADA_INCLUDE)
3482 AC_MSG_RESULT($ADA_INCLUDE)
3483 ])dnl
3484 dnl ---------------------------------------------------------------------------
3485 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
3486 dnl -------------------
3487 dnl Command-line option to specify where Ada objects will install.
3488 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
3489 AC_MSG_CHECKING(for ada-objects)
3490 CF_WITH_PATH(ada-objects,
3491    [  --with-ada-objects=DIR  Ada objects are in DIR],
3492    ADA_OBJECTS,
3493    PREFIX/lib/ada/adalib,
3494    [$]prefix/lib/ada/adalib)
3495 AC_SUBST(ADA_OBJECTS)
3496 AC_MSG_RESULT($ADA_OBJECTS)
3497 ])dnl
3498 dnl ---------------------------------------------------------------------------
3499 dnl CF_WITH_ADA_SHAREDLIB version: 2 updated: 2010/06/26 17:35:58
3500 dnl ---------------------
3501 dnl Command-line option to specify if an Ada95 shared-library should be built,
3502 dnl and optionally what its soname should be.
3503 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
3504 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
3505 AC_ARG_WITH(ada-sharedlib,
3506         [  --with-ada-sharedlib=XX build Ada95 shared-library],
3507         [with_ada_sharedlib=$withval],
3508         [with_ada_sharedlib=no])
3509 AC_MSG_RESULT($with_ada_sharedlib)
3510
3511 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
3512 MAKE_ADA_SHAREDLIB="#"
3513
3514 if test "x$with_ada_sharedlib" != xno
3515 then
3516         MAKE_ADA_SHAREDLIB=
3517         if test "x$with_ada_sharedlib" != xyes
3518         then
3519                 ADA_SHAREDLIB="$with_ada_sharedlib"
3520         fi
3521 fi
3522
3523 AC_SUBST(ADA_SHAREDLIB)
3524 AC_SUBST(MAKE_ADA_SHAREDLIB)
3525 ])dnl
3526 dnl ---------------------------------------------------------------------------
3527 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3528 dnl ------------------
3529 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3530 dnl libraries.
3531 AC_DEFUN([CF_WITH_CURSES_DIR],[
3532
3533 AC_MSG_CHECKING(for specific curses-directory)
3534 AC_ARG_WITH(curses-dir,
3535         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3536         [cf_cv_curses_dir=$withval],
3537         [cf_cv_curses_dir=no])
3538 AC_MSG_RESULT($cf_cv_curses_dir)
3539
3540 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3541 then
3542         CF_PATH_SYNTAX(withval)
3543         if test -d "$cf_cv_curses_dir"
3544         then
3545                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3546                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3547         fi
3548 fi
3549 ])dnl
3550 dnl ---------------------------------------------------------------------------
3551 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
3552 dnl ------------------
3553 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
3554 dnl "lib" prefix, e.g., because it used the dll naming convention.
3555 dnl
3556 dnl $1 = variable to set
3557 AC_DEFUN([CF_WITH_LIB_PREFIX],
3558 [
3559 AC_MSG_CHECKING(if you want to have a library-prefix)
3560 AC_ARG_WITH(lib-prefix,
3561         [  --with-lib-prefix       override library-prefix],
3562         [with_lib_prefix=$withval],
3563         [with_lib_prefix=auto])
3564 AC_MSG_RESULT($with_lib_prefix)
3565
3566 if test $with_lib_prefix = auto
3567 then
3568         CF_LIB_PREFIX($1)
3569 elif test $with_lib_prefix = no
3570 then
3571         LIB_PREFIX=
3572 else
3573         LIB_PREFIX=$with_lib_prefix
3574 fi
3575 ])dnl
3576 dnl ---------------------------------------------------------------------------
3577 dnl CF_WITH_PATH version: 10 updated: 2010/10/23 15:44:18
3578 dnl ------------
3579 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
3580 dnl defaulting to yes/no.
3581 dnl
3582 dnl $1 = option name
3583 dnl $2 = help-text
3584 dnl $3 = environment variable to set
3585 dnl $4 = default value, shown in the help-message, must be a constant
3586 dnl $5 = default value, if it's an expression & cannot be in the help-message
3587 dnl
3588 AC_DEFUN([CF_WITH_PATH],
3589 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
3590 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
3591 if ifelse([$5],,true,[test -n "$5"]) ; then
3592 CF_PATH_SYNTAX(withval)
3593 fi
3594 $3="$withval"
3595 AC_SUBST($3)dnl
3596 ])dnl
3597 dnl ---------------------------------------------------------------------------
3598 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 2 updated: 2011/12/10 18:58:47
3599 dnl -------------------------
3600 dnl Allow the choice of the pkg-config library directory to be overridden.
3601 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
3602 if test "$PKG_CONFIG" != none ; then
3603         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
3604         AC_ARG_WITH(pkg-config-libdir,
3605                 [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
3606                 [PKG_CONFIG_LIBDIR=$withval],
3607                 [PKG_CONFIG_LIBDIR=yes])
3608
3609         case x$PKG_CONFIG_LIBDIR in #(vi
3610         x/*) #(vi
3611                 ;;
3612         xyes) #(vi
3613                 # look for the library directory using the same prefix as the executable
3614                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
3615                 case x`(arch) 2>/dev/null` in #(vi
3616                 *64) #(vi
3617                         for cf_config in $cf_path/share $cf_path/lib64 $cf_path/lib32 $cf_path/lib
3618                         do
3619                                 if test -d $cf_config/pkgconfig
3620                                 then
3621                                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
3622                                         break
3623                                 fi
3624                         done
3625                         ;;
3626                 *)
3627                         PKG_CONFIG_LIBDIR=$cf_path/lib/pkgconfig
3628                         ;;
3629                 esac
3630                 ;;
3631         *)
3632                 ;;
3633         esac
3634
3635         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
3636 fi
3637
3638 AC_SUBST(PKG_CONFIG_LIBDIR)
3639 ])dnl
3640 dnl ---------------------------------------------------------------------------
3641 dnl CF_WITH_PTHREAD version: 5 updated: 2011/12/10 19:01:56
3642 dnl ---------------
3643 dnl Check for POSIX thread library.
3644 AC_DEFUN([CF_WITH_PTHREAD],
3645 [
3646 AC_MSG_CHECKING(if you want to link with the pthread library)
3647 AC_ARG_WITH(pthread,
3648     [  --with-pthread          use POSIX thread library],
3649     [with_pthread=$withval],
3650     [with_pthread=no])
3651 AC_MSG_RESULT($with_pthread)
3652
3653 if test "$with_pthread" != no ; then
3654     AC_CHECK_HEADER(pthread.h,[
3655         AC_DEFINE(HAVE_PTHREADS_H)
3656
3657         for cf_lib_pthread in pthread c_r
3658         do
3659             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
3660             cf_save_LIBS="$LIBS"
3661             CF_ADD_LIB($cf_lib_pthread)
3662             AC_TRY_LINK([
3663 #include <pthread.h>
3664 ],[
3665                 int rc = pthread_create(0,0,0,0);
3666                 int r2 = pthread_mutexattr_settype(0, 0);
3667 ],[with_pthread=yes],[with_pthread=no])
3668             LIBS="$cf_save_LIBS"
3669             AC_MSG_RESULT($with_pthread)
3670             test "$with_pthread" = yes && break
3671         done
3672
3673         if test "$with_pthread" = yes ; then
3674             CF_ADD_LIB($cf_lib_pthread)
3675             AC_DEFINE(HAVE_LIBPTHREADS)
3676         else
3677             AC_MSG_ERROR(Cannot link with pthread library)
3678         fi
3679     ])
3680 fi
3681 ])
3682 dnl ---------------------------------------------------------------------------
3683 dnl CF_XOPEN_SOURCE version: 42 updated: 2012/01/07 08:26:49
3684 dnl ---------------
3685 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
3686 dnl or adapt to the vendor's definitions to get equivalent functionality,
3687 dnl without losing the common non-POSIX features.
3688 dnl
3689 dnl Parameters:
3690 dnl     $1 is the nominal value for _XOPEN_SOURCE
3691 dnl     $2 is the nominal value for _POSIX_C_SOURCE
3692 AC_DEFUN([CF_XOPEN_SOURCE],[
3693
3694 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
3695 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
3696 cf_xopen_source=
3697
3698 case $host_os in #(vi
3699 aix[[4-7]]*) #(vi
3700         cf_xopen_source="-D_ALL_SOURCE"
3701         ;;
3702 cygwin) #(vi
3703         cf_XOPEN_SOURCE=600
3704         ;;
3705 darwin[[0-8]].*) #(vi
3706         cf_xopen_source="-D_APPLE_C_SOURCE"
3707         ;;
3708 darwin*) #(vi
3709         cf_xopen_source="-D_DARWIN_C_SOURCE"
3710         cf_XOPEN_SOURCE=
3711         ;;
3712 freebsd*|dragonfly*) #(vi
3713         # 5.x headers associate
3714         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
3715         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
3716         cf_POSIX_C_SOURCE=200112L
3717         cf_XOPEN_SOURCE=600
3718         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"