ncurses 6.0 - patch 20150822
[ncurses.git] / Ada95 / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 2010-2014,2015 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey
30 dnl
31 dnl $Id: configure.in,v 1.60 2015/04/18 18:49:57 tom Exp $
32 dnl Process this file with autoconf to produce a configure script.
33 dnl
34 dnl See http://invisible-island.net/autoconf/ for additional information.
35 dnl
36 dnl ---------------------------------------------------------------------------
37 AC_PREREQ(2.52.20030208)
38 AC_REVISION($Revision: 1.60 $)
39 AC_INIT(gen/gen.c)
40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
41
42 CF_TOP_BUILDDIR
43
44 CF_WITH_SYSTYPE
45
46 ###     Save the given $CFLAGS to allow user-override.
47 cf_user_CFLAGS="$CFLAGS"
48
49 ###     Default install-location
50 CF_CFG_DEFAULTS
51
52 ###     Checks for programs.
53 CF_PROG_CC(gnatgcc gcc cc)
54 AC_PROG_CPP
55 AC_PROG_GCC_TRADITIONAL
56 CF_PROG_CC_C_O(CC)
57
58 AC_ARG_PROGRAM
59
60 CF_PROG_AWK
61 CF_PROG_EGREP
62 AC_PROG_INSTALL
63 CF_PROG_LN_S
64
65 AC_SYS_LONG_FILE_NAMES
66
67 # if we find pkg-config, check if we should install the ".pc" files.
68 CF_PKG_CONFIG
69 CF_WITH_PKG_CONFIG_LIBDIR
70
71 AC_MSG_CHECKING(if you want to build test-programs)
72 AC_ARG_WITH(tests,
73         [  --without-tests         suppress build with test-programs],
74         [cf_with_tests=$withval],
75         [cf_with_tests=yes])
76 AC_MSG_RESULT($cf_with_tests)
77
78 AC_MSG_CHECKING(if we should assume mixed-case filenames)
79 AC_ARG_ENABLE(mixed-case,
80         [  --enable-mixed-case     tic should assume mixed-case filenames],
81         [enable_mixedcase=$enableval],
82         [enable_mixedcase=auto])
83 AC_MSG_RESULT($enable_mixedcase)
84 if test "$enable_mixedcase" = "auto" ; then
85         CF_MIXEDCASE_FILENAMES
86 else
87         cf_cv_mixedcase=$enable_mixedcase
88         if test "$enable_mixedcase" = "yes" ; then
89                 AC_DEFINE(MIXEDCASE_FILENAMES)
90         fi
91 fi
92
93 # do this after mixed-case option (tags/TAGS is not as important as tic).
94 AC_PROG_MAKE_SET
95 CF_MAKE_TAGS
96 CF_MAKEFLAGS
97
98 dnl These are standard among *NIX systems, but not when cross-compiling
99 AC_CHECK_TOOL(RANLIB, ranlib, ':')
100 AC_CHECK_TOOL(LD, ld, ld)
101 AC_CHECK_TOOL(AR, ar, ar)
102 CF_AR_FLAGS
103 CF_PATHSEP
104
105 dnl Special option for use by system-builders: the install-prefix is used to
106 dnl adjust the location into which the actual install is done, so that an
107 dnl archive can be built without modifying the host system's configuration.
108 AC_MSG_CHECKING(if you have specified an install-prefix)
109 AC_ARG_WITH(install-prefix,
110         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
111         [case "$withval" in
112         (yes|no)
113                 ;;
114         (*)     DESTDIR="$withval"
115                 ;;
116         esac])
117 AC_MSG_RESULT($DESTDIR)
118 AC_SUBST(DESTDIR)
119
120 ###############################################################################
121 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
122 # If we're cross-compiling, allow the user to override the tools and their
123 # options.  The configure script is oriented toward identifying the host
124 # compiler, etc., but we need a build compiler to generate parts of the source.
125 CF_BUILD_CC
126
127 ###############################################################################
128 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
129
130 ### Options to allow the user to specify the set of libraries which are used.
131 ### Use "--without-normal --with-shared" to allow the default model to be
132 ### shared, for example.
133 cf_list_models=""
134
135 AC_MSG_CHECKING(if you want to build shared C-objects)
136 AC_ARG_WITH(shared,
137         [  --with-shared           generate shared C-objects (needed for --with-ada-sharedlib)],
138         [with_shared=$withval],
139         [with_shared=no])
140 AC_MSG_RESULT($with_shared)
141 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
142
143 AC_MSG_CHECKING(for specified models)
144 test -z "$cf_list_models" && cf_list_models=normal
145 AC_MSG_RESULT($cf_list_models)
146
147 ### Use the first model as the default, and save its suffix for use in building
148 ### up test-applications.
149 AC_MSG_CHECKING(for default model)
150 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
151 AC_MSG_RESULT($DFT_LWR_MODEL)
152
153 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
154
155 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
156 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
157
158 CF_NCURSES_ADDON
159
160 CF_WITH_LIB_PREFIX(cf_prefix)
161
162 LIB_SUFFIX=
163 AC_SUBST(LIB_SUFFIX)
164
165 ###############################################################################
166
167 dnl Not all ports of gcc support the -g option
168
169 if test X"$CC_G_OPT" = X"" ; then
170         CC_G_OPT='-g'
171         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
172 fi
173 AC_SUBST(CC_G_OPT)
174
175 AC_MSG_CHECKING(for default loader flags)
176 case $DFT_LWR_MODEL in
177 (normal)  LD_MODEL=''   ;;
178 (debug)   LD_MODEL=$CC_G_OPT ;;
179 (profile) LD_MODEL='-pg';;
180 (shared)  LD_MODEL=''   ;;
181 esac
182 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
183 AC_MSG_RESULT($LD_MODEL)
184
185 CF_SHARED_OPTS
186
187 # The test/sample programs in the original tree link using rpath option.
188 # Make it optional for packagers.
189 if test -n "$LOCAL_LDFLAGS"
190 then
191         AC_MSG_CHECKING(if you want to link sample programs with rpath option)
192         AC_ARG_ENABLE(rpath-link,
193                 [  --enable-rpath-link     link sample programs with rpath option],
194                 [with_rpath_link=$enableval],
195                 [with_rpath_link=yes])
196         AC_MSG_RESULT($with_rpath_link)
197         if test "$with_rpath_link" = no
198         then
199                 LOCAL_LDFLAGS=
200                 LOCAL_LDFLAGS2=
201         fi
202 fi
203
204 ###############################################################################
205 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
206
207 ###   use option --enable-broken-linker to force on use of broken-linker support
208 AC_MSG_CHECKING(if you want broken-linker support code)
209 AC_ARG_ENABLE(broken_linker,
210         [  --enable-broken_linker  compile with broken-linker support code],
211         [with_broken_linker=$enableval],
212         [with_broken_linker=${BROKEN_LINKER:-no}])
213 AC_MSG_RESULT($with_broken_linker)
214
215 BROKEN_LINKER=0
216 if test "$with_broken_linker" = yes ; then
217         AC_DEFINE(BROKEN_LINKER)
218         BROKEN_LINKER=1
219 elif test "$DFT_LWR_MODEL" = shared ; then
220         case $cf_cv_system_name in
221         (cygwin*)
222                 AC_DEFINE(BROKEN_LINKER)
223                 BROKEN_LINKER=1
224                 CF_VERBOSE(cygwin linker is broken anyway)
225                 ;;
226         esac
227 fi
228 AC_SUBST(BROKEN_LINKER)
229
230 # Check to define _XOPEN_SOURCE "automatically"
231 CF_XOPEN_SOURCE
232
233 CF_LARGEFILE
234
235 ### Enable compiling-in rcs id's
236 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
237 AC_ARG_WITH(rcs-ids,
238         [  --with-rcs-ids          compile-in RCS identifiers],
239         [with_rcs_ids=$withval],
240         [with_rcs_ids=no])
241 AC_MSG_RESULT($with_rcs_ids)
242 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 if RCS identifiers should be compiled-in)])
243
244 ###############################################################################
245 CF_HELP_MESSAGE(Extensions:)
246
247 ### Note that some functions (such as const) are normally disabled anyway.
248 AC_MSG_CHECKING(if you want to build with function extensions)
249 AC_ARG_ENABLE(ext-funcs,
250         [  --disable-ext-funcs     disable function-extensions],
251         [with_ext_funcs=$enableval],
252         [with_ext_funcs=yes])
253 AC_MSG_RESULT($with_ext_funcs)
254 if test "$with_ext_funcs" = yes ; then
255         NCURSES_EXT_FUNCS=1
256         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 if we have use_default_colors function])
257         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 if we have ncurses extended functions])
258 else
259         NCURSES_EXT_FUNCS=0
260 fi
261 AC_SUBST(NCURSES_EXT_FUNCS)
262
263 ###   use option --enable-const to turn on use of const beyond that in XSI.
264 AC_MSG_CHECKING(for extended use of const keyword)
265 AC_ARG_ENABLE(const,
266         [  --enable-const          compile with extra/non-standard const],
267         [with_ext_const=$enableval],
268         [with_ext_const=no])
269 AC_MSG_RESULT($with_ext_const)
270 NCURSES_CONST='/*nothing*/'
271 if test "$with_ext_const" = yes ; then
272         NCURSES_CONST=const
273 fi
274 AC_SUBST(NCURSES_CONST)
275
276 ###############################################################################
277 # These options are relatively safe to experiment with.
278 CF_HELP_MESSAGE(Development Code:)
279 AC_MSG_CHECKING(if you want all development code)
280 AC_ARG_WITH(develop,
281         [  --without-develop       disable development options],
282         [with_develop=$withval],
283         [with_develop=no])
284 AC_MSG_RESULT($with_develop)
285
286 ###############################################################################
287 # These are just experimental, probably should not be in a package:
288 CF_HELP_MESSAGE(Experimental Code:)
289
290 # This is still experimental (20080329), but should ultimately be moved to
291 # the script-block --with-normal, etc.
292 CF_WITH_PTHREAD
293
294 AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
295 AC_ARG_ENABLE(weak-symbols,
296         [  --enable-weak-symbols   enable weak-symbols for pthreads],
297         [use_weak_symbols=$withval],
298         [use_weak_symbols=no])
299 AC_MSG_RESULT($use_weak_symbols)
300 if test "$use_weak_symbols" = yes ; then
301         CF_WEAK_SYMBOLS
302 else
303         cf_cv_weak_symbols=no
304 fi
305
306 if test $cf_cv_weak_symbols = yes ; then
307         AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
308 fi
309
310 PTHREAD=
311 if test "$with_pthread" = "yes" ; then
312         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use the pthreads library])
313         enable_reentrant=yes
314         if test $cf_cv_weak_symbols = yes ; then
315                 PTHREAD=-lpthread
316         fi
317 fi
318 AC_SUBST(PTHREAD)
319
320 # OpenSUSE is installing ncurses6, using reentrant option.
321 AC_CHECK_FUNC(_nc_TABSIZE,[assume_reentrant=yes], [assume_reentrant=no])
322
323 # Reentrant code has to be opaque; there's little advantage to making ncurses
324 # opaque outside of that, so there is no --enable-opaque option.  We can use
325 # this option without --with-pthreads, but this will be always set for
326 # pthreads.
327 AC_MSG_CHECKING(if you want experimental reentrant code)
328 AC_ARG_ENABLE(reentrant,
329         [  --enable-reentrant      compile with experimental reentrant code],
330         [with_reentrant=$enableval],
331         [with_reentrant=$assume_reentrant])
332 AC_MSG_RESULT($with_reentrant)
333 if test "$with_reentrant" = yes ; then
334         cf_cv_enable_reentrant=1
335         if test $cf_cv_weak_symbols = yes ; then
336                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
337         elif test "$assume_reentrant" = no ; then
338                 LIB_SUFFIX="t${LIB_SUFFIX}"
339         fi
340         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to compile with experimental reentrant code])
341 else
342         cf_cv_enable_reentrant=0
343 fi
344 AC_SUBST(cf_cv_enable_reentrant)
345
346 ### Allow using a different wrap-prefix
347 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
348         AC_MSG_CHECKING(for prefix used to wrap public variables)
349         AC_ARG_WITH(wrap-prefix,
350                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
351                 [NCURSES_WRAP_PREFIX=$withval],
352                 [NCURSES_WRAP_PREFIX=_nc_])
353         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
354 else
355         NCURSES_WRAP_PREFIX=_nc_
356 fi
357 AC_SUBST(NCURSES_WRAP_PREFIX)
358 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ ncurses internal prefix])
359
360 ###############################################################################
361 CF_HELP_MESSAGE(Testing/development Options:)
362
363 ###     use option --disable-echo to suppress full display compiling commands
364 CF_DISABLE_ECHO
365
366 ###     use option --enable-warnings to turn on all gcc warnings
367 AC_MSG_CHECKING(if you want to see compiler warnings)
368 AC_ARG_ENABLE(warnings,
369         [  --enable-warnings       build: turn on GCC compiler warnings],
370         [with_warnings=$enableval])
371 AC_MSG_RESULT($with_warnings)
372
373 if test "x$with_warnings" = "xyes"; then
374         CF_ADD_ADAFLAGS(-gnatg)
375         CF_GCC_WARNINGS(Wno-unknown-pragmas Wswitch-enum)
376 fi
377 CF_GCC_ATTRIBUTES
378
379 ###     use option --enable-assertions to turn on generation of assertion code
380 AC_MSG_CHECKING(if you want to enable runtime assertions)
381 AC_ARG_ENABLE(assertions,
382         [  --enable-assertions     test: turn on generation of assertion code],
383         [with_assertions=$enableval],
384         [with_assertions=no])
385 AC_MSG_RESULT($with_assertions)
386 if test -n "$GCC"
387 then
388         if test "$with_assertions" = no
389         then
390                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
391         else
392                 CF_ADD_ADAFLAGS(-gnata)
393         fi
394 fi
395
396 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
397 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
398
399 ###     use option --enable-expanded to generate certain macros as functions
400 AC_ARG_ENABLE(expanded,
401         [  --enable-expanded       test: generate functions for certain macros],
402         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 if ncurses macros should be expanded as functions])])
403
404 ###     use option --disable-macros to suppress macros in favor of functions
405 AC_ARG_ENABLE(macros,
406         [  --disable-macros        test: use functions rather than macros],
407         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 if ncurses macros should be expanded as functions])])
408
409 # Normally we only add trace() to the debug-library.  Allow this to be
410 # extended to all models of the ncurses library:
411 cf_all_traces=no
412 case "$CFLAGS $CPPFLAGS" in
413 (*-DTRACE*)
414         cf_all_traces=yes
415         ;;
416 esac
417
418 AC_MSG_CHECKING(whether to add trace feature to all models)
419 AC_ARG_WITH(trace,
420 [  --with-trace            test: add trace() function to all models of ncurses],
421 [cf_with_trace=$withval],
422 [cf_with_trace=$cf_all_traces])
423 AC_MSG_RESULT($cf_with_trace)
424
425 if test "$cf_with_trace" = yes ; then
426         ADA_TRACE=TRUE
427         CF_ADD_CFLAGS(-DTRACE)
428 else
429         ADA_TRACE=FALSE
430 fi
431
432 AC_SUBST(ADA_TRACE)
433
434 CF_DISABLE_GNAT_PROJECTS
435
436 ###     Checks for libraries.
437 case $cf_cv_system_name in
438 (*mingw32*)
439         ;;
440 (*)
441 AC_CHECK_FUNC(gettimeofday,
442         AC_DEFINE(HAVE_GETTIMEOFDAY),[
443
444 AC_CHECK_LIB(bsd, gettimeofday,
445         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday])
446         LIBS="$LIBS -lbsd")])dnl CLIX: bzero, select, gettimeofday
447         ;;
448 esac
449
450 ###     Checks for header files.
451 AC_STDC_HEADERS
452 AC_HEADER_DIRENT
453 AC_HEADER_TIME
454
455 ###     checks for compiler characteristics
456 AC_LANG_C
457 AC_C_CONST
458
459 ###     Checks for external-data
460 CF_LINK_DATAONLY
461
462 ###     Checks for library functions.
463 CF_MKSTEMP
464
465 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
466 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
467         CF_STRIP_G_OPT(CFLAGS)
468         CF_STRIP_G_OPT(CXXFLAGS)
469 fi
470
471 CF_HELP_MESSAGE(Ada95 Binding Options:)
472 cf_with_ada=yes
473 dnl Check for availability of GNU Ada Translator (GNAT).
474 dnl At the moment we support no other Ada95 compiler.
475 if test "$cf_with_ada" != "no" ; then
476         CF_PROG_GNAT
477         if test "$cf_cv_prog_gnat_correct" = yes; then
478                 CF_FIXUP_ADAFLAGS
479
480                 CF_GNATPREP_OPT_T
481
482                 CF_GNAT_GENERICS
483                 CF_GNAT_SIGINT
484                 CF_GNAT_PROJECTS
485
486                 CF_WITH_ADA_COMPILER
487
488                 cf_ada_package=terminal_interface
489                 AC_SUBST(cf_ada_package)
490
491                 CF_WITH_ADA_INCLUDE
492                 CF_WITH_ADA_OBJECTS
493                 CF_WITH_ADA_SHAREDLIB
494         else
495                 AC_MSG_ERROR(No usable Ada compiler found)
496         fi
497 else
498         AC_MSG_ERROR(The Ada compiler is needed for this package)
499 fi
500
501 ################################################################################
502
503 # not needed
504 TINFO_LDFLAGS2=
505 AC_SUBST(TINFO_LDFLAGS2)
506 TINFO_LIBS=
507 AC_SUBST(TINFO_LIBS)
508
509 ### Construct the list of include-directories to be generated
510 CF_INCLUDE_DIRS
511 CF_ADA_INCLUDE_DIRS
512
513 ### Build up pieces for makefile rules
514 AC_MSG_CHECKING(default library suffix)
515 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
516 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
517 AC_MSG_RESULT($DFT_ARG_SUFFIX)
518
519 AC_MSG_CHECKING(default library-dependency suffix)
520 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
521 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
522 AC_MSG_RESULT($DFT_DEP_SUFFIX)
523
524 AC_MSG_CHECKING(default object directory)
525 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
526 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
527 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
528
529 ### Set up low-level terminfo dependencies for makefiles.
530
531 if test "$DFT_LWR_MODEL" = shared ; then
532         case $cf_cv_system_name in
533         (cygwin*)
534                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
535                 ;;
536         (msys*)
537                 # "lib" files have ".dll.a" suffix, "msys-" files have ".dll"
538                 ;;
539         esac
540 fi
541
542 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}
543 AC_SUBST(USE_CFG_SUFFIX)
544
545 ### Construct the list of subdirectories for which we'll customize makefiles
546 ### with the appropriate compile-rules.
547
548 SUB_MAKEFILES="gen/adacurses${USE_ARG_SUFFIX}-config:gen/adacurses-config.in"
549
550 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as the library path-separator])
551
552 ### Now that we're done running tests, add the compiler-warnings, if any
553 CF_ADD_CFLAGS($EXTRA_CFLAGS)
554
555 ################################################################################
556
557 TEST_ARG2=
558 AC_SUBST(TEST_ARG2)
559
560 TEST_LIBS2=
561 AC_SUBST(TEST_LIBS2)
562
563 dnl for separate build, this is good enough for "sh $(top_srcdir)/misc/shlib"
564 NCURSES_SHLIB2="sh -c"
565 AC_SUBST(NCURSES_SHLIB2)
566
567 ADA_SUBDIRS="include gen src doc"
568 if test "x$cf_with_tests" != "xno" ; then
569         ADA_SUBDIRS="$ADA_SUBDIRS samples"
570 fi
571 for cf_dir in $ADA_SUBDIRS
572 do
573         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
574 done
575 AC_SUBST(ADA_SUBDIRS)
576
577 NCURSES_TREE="#"
578 AC_SUBST(NCURSES_TREE)
579
580 EXTERNAL_TREE=
581 AC_SUBST(EXTERNAL_TREE)
582
583 # match layout used by make-tar.sh
584 ADAHTML_DIR=../doc/ada
585 AC_SUBST(ADAHTML_DIR)
586
587 AC_OUTPUT( \
588         $SUB_MAKEFILES \
589         doc/adacurses${DFT_ARG_SUFFIX}-config.1:doc/MKada_config.in \
590         Makefile,[
591 if test -z "$USE_OLD_MAKERULES" ; then
592         $AWK -f $srcdir/mk-1st.awk <$srcdir/src/modules >>src/Makefile
593 fi
594 ],[
595 ### Special initialization commands, used to pass information from the
596 ### configuration-run into config.status
597
598 AWK="$AWK"
599 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
600 DFT_LWR_MODEL="$DFT_LWR_MODEL"
601 LIB_NAME="$LIB_NAME"
602 LIB_PREFIX="$LIB_PREFIX"
603 LIB_SUFFIX="$LIB_SUFFIX"
604 LN_S="$LN_S"
605 NCURSES_MAJOR="$NCURSES_MAJOR"
606 NCURSES_MINOR="$NCURSES_MINOR"
607 NCURSES_PATCH="$NCURSES_PATCH"
608 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
609 cf_cv_abi_version="$cf_cv_abi_version"
610 cf_cv_rel_version="$cf_cv_rel_version"
611 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
612 cf_cv_shared_soname='$cf_cv_shared_soname'
613 cf_cv_shlib_version="$cf_cv_shlib_version"
614 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
615 cf_cv_system_name="$cf_cv_system_name"
616 host="$host"
617 target="$target"
618
619 ],cat)dnl
620 ${MAKE:-make} preinstall