aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2022,2023 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: aclocal.m4,v 1.1026 2023/01/14 14:00:15 tom Exp $
  33 dnl Macros used in NCURSES auto-configuration script.
  34 dnl
  35 dnl These macros are maintained separately from NCURSES.  The copyright on
  36 dnl this file applies to the aggregation of macros and does not affect use of
  37 dnl these macros in other applications.
  38 dnl
  39 dnl See these pages for additional information:
  40 dnl             https://invisible-island.net/autoconf/
  41 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  42 dnl
  43 dnl ---------------------------------------------------------------------------
  44 dnl ---------------------------------------------------------------------------
  45 dnl AM_LANGINFO_CODESET version: 7 updated: 2023/01/11 04:05:23
  46 dnl -------------------
  47 dnl Inserted as requested by gettext 0.10.40
  48 dnl File from /usr/share/aclocal
  49 dnl codeset.m4
  50 dnl ====================
  51 dnl serial AM1
  52 dnl
  53 dnl From Bruno Haible.
  54 AC_DEFUN([AM_LANGINFO_CODESET],
  55 [
  56 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  57         [AC_TRY_LINK([
  58 $ac_includes_default
  59 #include <langinfo.h>],
  60         [char* cs = nl_langinfo(CODESET); (void)cs],
  61         am_cv_langinfo_codeset=yes,
  62         am_cv_langinfo_codeset=no)
  63         ])
  64         if test "$am_cv_langinfo_codeset" = yes; then
  65                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  66                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  67         fi
  68 ])dnl
  69 dnl ---------------------------------------------------------------------------
  70 dnl CF_ABI_DEFAULTS version: 4 updated: 2023/01/07 16:32:06
  71 dnl ---------------
  72 dnl Provide configure-script defaults for different ncurses ABIs.
  73 AC_DEFUN([CF_ABI_DEFAULTS],[
  74 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  75
  76 # ABI 5 defaults:
  77 cf_dft_ccharw_max=5
  78 cf_dft_chtype=auto
  79 cf_dft_ext_colors=no
  80 cf_dft_ext_const=no
  81 cf_dft_ext_mouse=no
  82 cf_dft_ext_putwin=no
  83 cf_dft_ext_spfuncs=no
  84 cf_dft_filter_syms=no
  85 cf_dft_interop=no
  86 cf_dft_mmask_t=auto
  87 cf_dft_opaque_curses=no
  88 cf_dft_ordinate_type=short
  89 cf_dft_signed_char=no
  90 cf_dft_tparm_arg=long
  91 cf_dft_with_lp64=no
  92
  93 # ABI 6 defaults:
  94 case x$cf_cv_abi_default in
  95 (x[[6789]])
  96         cf_dft_chtype=uint32_t
  97         cf_dft_ext_colors=yes
  98         cf_dft_ext_const=yes
  99         cf_dft_ext_mouse=yes
 100         cf_dft_ext_putwin=yes
 101         cf_dft_ext_spfuncs=yes
 102         cf_dft_filter_syms=yes
 103         cf_dft_interop=yes
 104         cf_dft_mmask_t=uint32_t
 105         cf_dft_tparm_arg=intptr_t
 106         cf_dft_with_lp64=yes
 107         ;;
 108 esac
 109
 110 # ABI 7 defaults:
 111 case x$cf_cv_abi_default in
 112 (x[[789]])
 113         cf_dft_ccharw_max=6
 114         cf_dft_mmask_t=uint64_t
 115         cf_dft_opaque_curses=yes
 116         cf_dft_ordinate_type=int
 117         cf_dft_signed_char=yes
 118         # also: remove the wgetch-events feature in ABI 7
 119         ;;
 120 esac
 121 ])dnl
 122 dnl ---------------------------------------------------------------------------
 123 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 124 dnl ------------------
 125 dnl Conditionally generate script according to whether we're using a given autoconf.
 126 dnl
 127 dnl $1 = version to compare against
 128 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 129 dnl $3 = code to use if AC_ACVERSION is older than $1.
 130 define([CF_ACVERSION_CHECK],
 131 [
 132 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 133 ifdef([m4_version_compare],
 134 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 135 [CF_ACVERSION_COMPARE(
 136 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 137 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 138 dnl ---------------------------------------------------------------------------
 139 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 140 dnl --------------------
 141 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 142 dnl                      MAJOR2, MINOR2, TERNARY2,
 143 dnl                      PRINTABLE2, not FOUND, FOUND)
 144 define([CF_ACVERSION_COMPARE],
 145 [ifelse(builtin([eval], [$2 < $5]), 1,
 146 [ifelse([$8], , ,[$8])],
 147 [ifelse([$9], , ,[$9])])])dnl
 148 dnl ---------------------------------------------------------------------------
 149 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 150 dnl -------------------
 151 dnl Construct the list of include-options for the C programs in the Ada95
 152 dnl binding.
 153 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 154 [
 155 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 156 if test "$srcdir" != "."; then
 157         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 158 fi
 159 if test "$GCC" != yes; then
 160         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 161 elif test "$includedir" != "/usr/include"; then
 162         if test "$includedir" = '${prefix}/include' ; then
 163                 if test x$prefix != x/usr ; then
 164                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 165                 fi
 166         else
 167                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 168         fi
 169 fi
 170 AC_SUBST(ACPPFLAGS)
 171 ])dnl
 172 dnl ---------------------------------------------------------------------------
 173 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 174 dnl ---------------
 175 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 176 AC_DEFUN([CF_ADD_ADAFLAGS],[
 177         ADAFLAGS="$ADAFLAGS $1"
 178         AC_SUBST(ADAFLAGS)
 179 ])dnl
 180 dnl ---------------------------------------------------------------------------
 181 dnl CF_ADD_CFLAGS version: 15 updated: 2020/12/31 10:54:15
 182 dnl -------------
 183 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 184 dnl $1 = flags to add
 185 dnl $2 = if given makes this macro verbose.
 186 dnl
 187 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 188 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 189 dnl confused by the quotes (which require backslashes to keep them usable).
 190 AC_DEFUN([CF_ADD_CFLAGS],
 191 [
 192 cf_fix_cppflags=no
 193 cf_new_cflags=
 194 cf_new_cppflags=
 195 cf_new_extra_cppflags=
 196
 197 for cf_add_cflags in $1
 198 do
 199 case "$cf_fix_cppflags" in
 200 (no)
 201         case "$cf_add_cflags" in
 202         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 203                 case "$cf_add_cflags" in
 204                 (-D*)
 205                         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 206
 207                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 208                                 && test -z "${cf_tst_cflags}" \
 209                                 && cf_fix_cppflags=yes
 210
 211                         if test "$cf_fix_cppflags" = yes ; then
 212                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 213                                 continue
 214                         elif test "${cf_tst_cflags}" = "\"'" ; then
 215                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 216                                 continue
 217                         fi
 218                         ;;
 219                 esac
 220                 case "$CPPFLAGS" in
 221                 (*$cf_add_cflags)
 222                         ;;
 223                 (*)
 224                         case "$cf_add_cflags" in
 225                         (-D*)
 226                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 227                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 228                                 ;;
 229                         esac
 230                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 231                         ;;
 232                 esac
 233                 ;;
 234         (*)
 235                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 236                 ;;
 237         esac
 238         ;;
 239 (yes)
 240         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 241
 242         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^[[^"]]*"'\''//'`
 243
 244         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 245                 && test -z "${cf_tst_cflags}" \
 246                 && cf_fix_cppflags=no
 247         ;;
 248 esac
 249 done
 250
 251 if test -n "$cf_new_cflags" ; then
 252         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 253         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 254 fi
 255
 256 if test -n "$cf_new_cppflags" ; then
 257         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 258         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 259 fi
 260
 261 if test -n "$cf_new_extra_cppflags" ; then
 262         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 263         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 264 fi
 265
 266 AC_SUBST(EXTRA_CPPFLAGS)
 267
 268 ])dnl
 269 dnl ---------------------------------------------------------------------------
 270 dnl CF_ADD_CXXFLAGS version: 1 updated: 2020/04/04 16:16:13
 271 dnl ---------------
 272 dnl Copy non-preprocessor flags to $CXXFLAGS, preprocessor flags to $CPPFLAGS
 273 dnl The second parameter if given makes this macro verbose.
 274 dnl
 275 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 276 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 277 dnl confused by the quotes (which require backslashes to keep them usable).
 278 AC_DEFUN([CF_ADD_CXXFLAGS],
 279 [
 280 cf_save_CXXFLAGS="$CFLAGS"
 281 CFLAGS="$CXXFLAGS"
 282 CF_ADD_CFLAGS($1 ifelse($2,,,[,$2]))
 283 CXXFLAGS="$CFLAGS"
 284 CFLAGS="$cf_save_CXXFLAGS"
 285 ])dnl
 286 dnl ---------------------------------------------------------------------------
 287 dnl CF_ADD_INCDIR version: 17 updated: 2021/09/04 06:35:04
 288 dnl -------------
 289 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it is
 290 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 291 dnl but old versions (and some misinstalled ones) need that.  To make things
 292 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 293 dnl the include-path).
 294 AC_DEFUN([CF_ADD_INCDIR],
 295 [
 296 if test -n "$1" ; then
 297   for cf_add_incdir in $1
 298   do
 299         while test "$cf_add_incdir" != /usr/include
 300         do
 301           if test -d "$cf_add_incdir"
 302           then
 303                 cf_have_incdir=no
 304                 if test -n "$CFLAGS$CPPFLAGS" ; then
 305                   # a loop is needed to ensure we can add subdirs of existing dirs
 306                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 307                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 308                           cf_have_incdir=yes; break
 309                         fi
 310                   done
 311                 fi
 312
 313                 if test "$cf_have_incdir" = no ; then
 314                   if test "$cf_add_incdir" = /usr/local/include ; then
 315                         if test "$GCC" = yes
 316                         then
 317                           cf_save_CPPFLAGS=$CPPFLAGS
 318                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 319                           AC_TRY_COMPILE([#include <stdio.h>],
 320                                   [printf("Hello")],
 321                                   [],
 322                                   [cf_have_incdir=yes])
 323                           CPPFLAGS=$cf_save_CPPFLAGS
 324                         fi
 325                   fi
 326                 fi
 327
 328                 if test "$cf_have_incdir" = no ; then
 329                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 330                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 331
 332                   cf_top_incdir=`echo "$cf_add_incdir" | sed -e 's%/include/.*$%/include%'`
 333                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 334                   cf_add_incdir="$cf_top_incdir"
 335                 else
 336                   break
 337                 fi
 338           else
 339                 break
 340           fi
 341         done
 342   done
 343 fi
 344 ])dnl
 345 dnl ---------------------------------------------------------------------------
 346 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 347 dnl ----------
 348 dnl Add a library, used to enforce consistency.
 349 dnl
 350 dnl $1 = library to add, without the "-l"
 351 dnl $2 = variable to update (default $LIBS)
 352 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 353 dnl ---------------------------------------------------------------------------
 354 dnl CF_ADD_LIBDIR version: 11 updated: 2020/12/31 20:19:42
 355 dnl -------------
 356 dnl     Adds to the library-path
 357 dnl
 358 dnl     Some machines have trouble with multiple -L options.
 359 dnl
 360 dnl $1 is the (list of) directory(s) to add
 361 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 362 dnl
 363 AC_DEFUN([CF_ADD_LIBDIR],
 364 [
 365 if test -n "$1" ; then
 366         for cf_add_libdir in $1
 367         do
 368                 if test "$cf_add_libdir" = /usr/lib ; then
 369                         :
 370                 elif test -d "$cf_add_libdir"
 371                 then
 372                         cf_have_libdir=no
 373                         if test -n "$LDFLAGS$LIBS" ; then
 374                                 # a loop is needed to ensure we can add subdirs of existing dirs
 375                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 376                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 377                                                 cf_have_libdir=yes; break
 378                                         fi
 379                                 done
 380                         fi
 381                         if test "$cf_have_libdir" = no ; then
 382                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 383                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 384                         fi
 385                 fi
 386         done
 387 fi
 388 ])dnl
 389 dnl ---------------------------------------------------------------------------
 390 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
 391 dnl -----------
 392 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 393 dnl prepended to an existing list, since their dependencies are assumed to
 394 dnl already exist in the list.
 395 dnl
 396 dnl $1 = libraries to add, with the "-l", etc.
 397 dnl $2 = variable to update (default $LIBS)
 398 AC_DEFUN([CF_ADD_LIBS],[
 399 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
 400 # reverse order
 401 cf_add_0lib=
 402 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
 403 # filter duplicates
 404 for cf_add_1lib in $cf_add_0lib; do
 405         for cf_add_2lib in $cf_add_libs; do
 406                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
 407                         cf_add_1lib=
 408                         break
 409                 fi
 410         done
 411         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
 412 done
 413 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 414 ])dnl
 415 dnl ---------------------------------------------------------------------------
 416 dnl CF_ADD_SUBDIR_PATH version: 5 updated: 2020/12/31 20:19:42
 417 dnl ------------------
 418 dnl Append to a search-list for a nonstandard header/lib-file
 419 dnl     $1 = the variable to return as result
 420 dnl     $2 = the package name
 421 dnl     $3 = the subdirectory, e.g., bin, include or lib
 422 dnl $4 = the directory under which we will test for subdirectories
 423 dnl $5 = a directory that we do not want $4 to match
 424 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 425 [
 426 test "x$4" != "x$5" && \
 427 test -d "$4" && \
 428 ifelse([$5],NONE,,[{ test -z "$5" || test "x$5" = xNONE || test "x$4" != "x$5"; } &&]) {
 429         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 430         test -d "$4/$3" &&          $1="[$]$1 $4/$3"
 431         test -d "$4/$3/$2" &&       $1="[$]$1 $4/$3/$2"
 432         test -d "$4/$3/$2/$3" &&    $1="[$]$1 $4/$3/$2/$3"
 433         test -d "$4/$2/$3" &&       $1="[$]$1 $4/$2/$3"
 434         test -d "$4/$2/$3/$2" &&    $1="[$]$1 $4/$2/$3/$2"
 435 }
 436 ])dnl
 437 dnl ---------------------------------------------------------------------------
 438 dnl CF_APPEND_CFLAGS version: 3 updated: 2021/09/05 17:25:40
 439 dnl ----------------
 440 dnl Use CF_ADD_CFLAGS after first checking for potential redefinitions.
 441 dnl $1 = flags to add
 442 dnl $2 = if given makes this macro verbose.
 443 define([CF_APPEND_CFLAGS],
 444 [
 445 for cf_add_cflags in $1
 446 do
 447         case "x$cf_add_cflags" in
 448         (x-[[DU]]*)
 449                 CF_REMOVE_CFLAGS($cf_add_cflags,CFLAGS,[$2])
 450                 CF_REMOVE_CFLAGS($cf_add_cflags,CPPFLAGS,[$2])
 451                 ;;
 452         esac
 453         CF_ADD_CFLAGS([$cf_add_cflags],[$2])
 454 done
 455 ])dnl
 456 dnl ---------------------------------------------------------------------------
 457 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 458 dnl --------------
 459 dnl use this macro for appending text without introducing an extra blank at
 460 dnl the beginning
 461 define([CF_APPEND_TEXT],
 462 [
 463         test -n "[$]$1" && $1="[$]$1 "
 464         $1="[$]{$1}$2"
 465 ])dnl
 466 dnl ---------------------------------------------------------------------------
 467 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 468 dnl --------------
 469 dnl Allow user to disable a normally-on option.
 470 AC_DEFUN([CF_ARG_DISABLE],
 471 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 472 dnl ---------------------------------------------------------------------------
 473 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 474 dnl -------------
 475 dnl Allow user to enable a normally-off option.
 476 AC_DEFUN([CF_ARG_ENABLE],
 477 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 478 dnl ---------------------------------------------------------------------------
 479 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 480 dnl -------------
 481 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 482 dnl values.
 483 dnl
 484 dnl Parameters:
 485 dnl $1 = option name
 486 dnl $2 = help-string
 487 dnl $3 = action to perform if option is not default
 488 dnl $4 = action if perform if option is default
 489 dnl $5 = default option value (either 'yes' or 'no')
 490 AC_DEFUN([CF_ARG_OPTION],
 491 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 492         if test "$enableval" != "$5" ; then
 493 ifelse([$3],,[    :]dnl
 494 ,[    $3]) ifelse([$4],,,[
 495         else
 496                 $4])
 497         fi],[enableval=$5 ifelse([$4],,,[
 498         $4
 499 ])dnl
 500 ])])dnl
 501 dnl ---------------------------------------------------------------------------
 502 dnl CF_AR_FLAGS version: 9 updated: 2021/01/01 13:31:04
 503 dnl -----------
 504 dnl Check for suitable "ar" (archiver) options for updating an archive.
 505 dnl
 506 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 507 dnl as well as a workaround for breakage of make's archive rules by the GNU
 508 dnl binutils "ar" program.
 509 AC_DEFUN([CF_AR_FLAGS],[
 510 AC_REQUIRE([CF_PROG_AR])
 511
 512 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 513         case "$cf_cv_system_name" in
 514         (*-msvc*)
 515                 cf_cv_ar_flags=''
 516                 cat >mk_static_lib.sh <<-EOF
 517                 #!$SHELL
 518                 MSVC_BIN="[$]AR"
 519                 out="\[$]1"
 520                 shift
 521                 exec \[$]MSVC_BIN -out:"\[$]out" \[$]@
 522                 EOF
 523                 chmod +x mk_static_lib.sh
 524                 AR=`pwd`/mk_static_lib.sh
 525                 ;;
 526         (*)
 527                 cf_cv_ar_flags=unknown
 528                 for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 529                 do
 530
 531                         # check if $ARFLAGS already contains this choice
 532                         if test "x$ARFLAGS" != "x" ; then
 533                                 cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 534                                 if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 535                                         cf_cv_ar_flags=
 536                                         break
 537                                 fi
 538                         fi
 539
 540                         rm -f "conftest.$ac_cv_objext"
 541                         rm -f conftest.a
 542
 543                         cat >"conftest.$ac_ext" <<EOF
 544 #line __oline__ "configure"
 545 int     testdata[[3]] = { 123, 456, 789 };
 546 EOF
 547                         if AC_TRY_EVAL(ac_compile) ; then
 548                                 echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 549                                 $AR $ARFLAGS "$cf_ar_flags" conftest.a "conftest.$ac_cv_objext" 2>&AC_FD_CC 1>/dev/null
 550                                 if test -f conftest.a ; then
 551                                         cf_cv_ar_flags="$cf_ar_flags"
 552                                         break
 553                                 fi
 554                         else
 555                                 CF_VERBOSE(cannot compile test-program)
 556                                 break
 557                         fi
 558                 done
 559                 rm -f conftest.a "conftest.$ac_ext" "conftest.$ac_cv_objext"
 560                 ;;
 561         esac
 562 ])
 563
 564 if test -n "$ARFLAGS" ; then
 565         if test -n "$cf_cv_ar_flags" ; then
 566                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 567         fi
 568 else
 569         ARFLAGS=$cf_cv_ar_flags
 570 fi
 571
 572 AC_SUBST(ARFLAGS)
 573 ])
 574 dnl ---------------------------------------------------------------------------
 575 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 576 dnl -----------------
 577 dnl Check if awk can handle big strings using printf.  Some older versions of
 578 dnl awk choke on large strings passed via "%s".
 579 dnl
 580 dnl $1 = desired string size
 581 dnl $2 = variable to set with result
 582 AC_DEFUN([CF_AWK_BIG_PRINTF],
 583 [
 584         case x$AWK in
 585         (x)
 586                 eval $2=no
 587                 ;;
 588         (*)
 589                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 590                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 591                         eval $2=yes
 592                 else
 593                         eval $2=no
 594                 fi
 595                 ;;
 596         esac
 597 ])dnl
 598 dnl ---------------------------------------------------------------------------
 599 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 600 dnl ------------
 601 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 602 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 603 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 604 dnl
 605 dnl Treat the configuration-variable specially here, since we're directly
 606 dnl substituting its value (i.e., 1/0).
 607 dnl
 608 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 609 AC_DEFUN([CF_BOOL_DECL],
 610 [
 611 AC_MSG_CHECKING(if we should include stdbool.h)
 612
 613 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 614         AC_TRY_COMPILE([],[bool foo = false],
 615                 [cf_cv_header_stdbool_h=0],
 616                 [AC_TRY_COMPILE([
 617 #ifndef __BEOS__
 618 #include <stdbool.h>
 619 #endif
 620 ],[bool foo = false],
 621                         [cf_cv_header_stdbool_h=1],
 622                         [cf_cv_header_stdbool_h=0])])])
 623
 624 if test "$cf_cv_header_stdbool_h" = 1
 625 then    AC_MSG_RESULT(yes)
 626 else    AC_MSG_RESULT(no)
 627 fi
 628
 629 AC_MSG_CHECKING([for builtin bool type])
 630
 631 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 632         AC_TRY_COMPILE([
 633 #include <stdio.h>
 634 #include <sys/types.h>
 635 ],[bool x = false],
 636                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 637                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 638         ])
 639
 640 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 641 then    AC_MSG_RESULT(yes)
 642 else    AC_MSG_RESULT(no)
 643 fi
 644 ])dnl
 645 dnl ---------------------------------------------------------------------------
 646 dnl CF_BOOL_SIZE version: 19 updated: 2023/01/05 18:00:14
 647 dnl ------------
 648 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 649 dnl Don't bother looking for bool.h, since it has been deprecated.
 650 dnl
 651 dnl If the current compiler is C rather than C++, we get the bool definition
 652 dnl from <stdbool.h>.
 653 AC_DEFUN([CF_BOOL_SIZE],
 654 [
 655 AC_CHECK_SIZEOF(bool,,[
 656 #include <stdlib.h>
 657 #include <stdio.h>
 658
 659 #if defined(__cplusplus)
 660
 661 #ifdef HAVE_GXX_BUILTIN_H
 662 #include <g++/builtin.h>
 663 #elif HAVE_GPP_BUILTIN_H
 664 #include <gpp/builtin.h>
 665 #elif HAVE_BUILTIN_H
 666 #include <builtin.h>
 667 #endif
 668
 669 #else
 670
 671 #if $cf_cv_header_stdbool_h
 672 #include <stdbool.h>
 673 #endif
 674
 675 #endif
 676 ])
 677
 678 AC_CACHE_CHECK(for type of bool, cf_cv_type_of_bool,[
 679         rm -f cf_test.out
 680         AC_TRY_RUN([
 681 $ac_includes_default
 682
 683 #if defined(__cplusplus)
 684
 685 #ifdef HAVE_GXX_BUILTIN_H
 686 #include <g++/builtin.h>
 687 #elif HAVE_GPP_BUILTIN_H
 688 #include <gpp/builtin.h>
 689 #elif HAVE_BUILTIN_H
 690 #include <builtin.h>
 691 #endif
 692
 693 #else
 694
 695 #if $cf_cv_header_stdbool_h
 696 #include <stdbool.h>
 697 #endif
 698
 699 #endif
 700
 701 int main(void)
 702 {
 703         FILE *fp = fopen("cf_test.out", "w");
 704         if (fp != 0) {
 705                 bool x = true;
 706                 if ((bool)(-x) >= 0)
 707                         fputs("unsigned ", fp);
 708                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 709                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 710                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 711                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 712                 fclose(fp);
 713         }
 714         ${cf_cv_main_return:-return}(0);
 715 }
 716                 ],
 717                 [cf_cv_type_of_bool=`cat cf_test.out`
 718                  if test -z "$cf_cv_type_of_bool"; then
 719                    cf_cv_type_of_bool=unknown
 720                  fi],
 721                 [cf_cv_type_of_bool=unknown],
 722                 [
 723                 case x$ac_cv_sizeof_bool in
 724                 (x1) cf_cv_type_of_bool="unsigned char";;
 725                 (x2) cf_cv_type_of_bool="unsigned short";;
 726                 (x4) cf_cv_type_of_bool="unsigned int";;
 727                 (x8) cf_cv_type_of_bool="unsigned long";;
 728                 (*)  cf_cv_type_of_bool=unknown;;
 729                 esac
 730                 ])
 731         rm -f cf_test.out
 732 ])
 733
 734 if test "$cf_cv_type_of_bool" = unknown ; then
 735         case .$NCURSES_BOOL in
 736         (.auto|.) NCURSES_BOOL=unsigned;;
 737         esac
 738         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 739         cf_cv_type_of_bool=$NCURSES_BOOL
 740 fi
 741 ])dnl
 742 dnl ---------------------------------------------------------------------------
 743 dnl CF_BUILD_CC version: 11 updated: 2022/12/04 15:40:08
 744 dnl -----------
 745 dnl If we're cross-compiling, allow the user to override the tools and their
 746 dnl options.  The configure script is oriented toward identifying the host
 747 dnl compiler, etc., but we need a build compiler to generate parts of the
 748 dnl source.
 749 dnl
 750 dnl $1 = default for $CPPFLAGS
 751 dnl $2 = default for $LIBS
 752 AC_DEFUN([CF_BUILD_CC],[
 753 CF_ACVERSION_CHECK(2.52,,
 754         [AC_REQUIRE([CF_PROG_EXT])])
 755 if test "$cross_compiling" = yes ; then
 756
 757         # defaults that we might want to override
 758         : ${BUILD_CFLAGS:=''}
 759         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 760         : ${BUILD_LDFLAGS:=''}
 761         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 762         : ${BUILD_EXEEXT:='$x'}
 763         : ${BUILD_OBJEXT:='o'}
 764
 765         AC_ARG_WITH(build-cc,
 766                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 767                 [BUILD_CC="$withval"],
 768                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 769         AC_MSG_CHECKING(for native build C compiler)
 770         AC_MSG_RESULT($BUILD_CC)
 771
 772         AC_MSG_CHECKING(for native build C preprocessor)
 773         AC_ARG_WITH(build-cpp,
 774                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 775                 [BUILD_CPP="$withval"],
 776                 [BUILD_CPP='${BUILD_CC} -E'])
 777         AC_MSG_RESULT($BUILD_CPP)
 778
 779         AC_MSG_CHECKING(for native build C flags)
 780         AC_ARG_WITH(build-cflags,
 781                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 782                 [BUILD_CFLAGS="$withval"])
 783         AC_MSG_RESULT($BUILD_CFLAGS)
 784
 785         AC_MSG_CHECKING(for native build C preprocessor-flags)
 786         AC_ARG_WITH(build-cppflags,
 787                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 788                 [BUILD_CPPFLAGS="$withval"])
 789         AC_MSG_RESULT($BUILD_CPPFLAGS)
 790
 791         AC_MSG_CHECKING(for native build linker-flags)
 792         AC_ARG_WITH(build-ldflags,
 793                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 794                 [BUILD_LDFLAGS="$withval"])
 795         AC_MSG_RESULT($BUILD_LDFLAGS)
 796
 797         AC_MSG_CHECKING(for native build linker-libraries)
 798         AC_ARG_WITH(build-libs,
 799                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 800                 [BUILD_LIBS="$withval"])
 801         AC_MSG_RESULT($BUILD_LIBS)
 802
 803         # this assumes we're on Unix.
 804         BUILD_EXEEXT=
 805         BUILD_OBJEXT=o
 806
 807         : ${BUILD_CC:='${CC}'}
 808
 809         AC_MSG_CHECKING(if the build-compiler "$BUILD_CC" works)
 810
 811         cf_save_crossed=$cross_compiling
 812         cf_save_ac_link=$ac_link
 813         cross_compiling=no
 814         cf_build_cppflags=$BUILD_CPPFLAGS
 815         test "$cf_build_cppflags" = "#" && cf_build_cppflags=
 816         ac_link='$BUILD_CC -o "conftest$ac_exeext" $BUILD_CFLAGS $cf_build_cppflags $BUILD_LDFLAGS "conftest.$ac_ext" $BUILD_LIBS >&AS_MESSAGE_LOG_FD'
 817
 818         AC_TRY_RUN([#include <stdio.h>
 819                 int main(int argc, char *argv[])
 820                 {
 821                         ${cf_cv_main_return:-return}(argc < 0 || argv == 0 || argv[0] == 0);
 822                 }
 823         ],
 824                 cf_ok_build_cc=yes,
 825                 cf_ok_build_cc=no,
 826                 cf_ok_build_cc=unknown)
 827
 828         cross_compiling=$cf_save_crossed
 829         ac_link=$cf_save_ac_link
 830
 831         AC_MSG_RESULT($cf_ok_build_cc)
 832
 833         if test "$cf_ok_build_cc" != yes
 834         then
 835                 AC_MSG_ERROR([Cross-build requires two compilers.
 836 Use --with-build-cc to specify the native compiler.])
 837         fi
 838
 839 else
 840         : ${BUILD_CC:='${CC}'}
 841         : ${BUILD_CPP:='${CPP}'}
 842         : ${BUILD_CFLAGS:='${CFLAGS}'}
 843         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 844         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 845         : ${BUILD_LIBS:='${LIBS}'}
 846         : ${BUILD_EXEEXT:='$x'}
 847         : ${BUILD_OBJEXT:='o'}
 848 fi
 849
 850 AC_SUBST(BUILD_CC)
 851 AC_SUBST(BUILD_CPP)
 852 AC_SUBST(BUILD_CFLAGS)
 853 AC_SUBST(BUILD_CPPFLAGS)
 854 AC_SUBST(BUILD_LDFLAGS)
 855 AC_SUBST(BUILD_LIBS)
 856 AC_SUBST(BUILD_EXEEXT)
 857 AC_SUBST(BUILD_OBJEXT)
 858 ])dnl
 859 dnl ---------------------------------------------------------------------------
 860 dnl CF_C11_NORETURN version: 3 updated: 2021/03/28 11:36:23
 861 dnl ---------------
 862 AC_DEFUN([CF_C11_NORETURN],
 863 [
 864 AC_MSG_CHECKING(if you want to use C11 _Noreturn feature)
 865 CF_ARG_ENABLE(stdnoreturn,
 866         [  --enable-stdnoreturn    enable C11 _Noreturn feature for diagnostics],
 867         [enable_stdnoreturn=yes],
 868         [enable_stdnoreturn=no])
 869 AC_MSG_RESULT($enable_stdnoreturn)
 870
 871 if test $enable_stdnoreturn = yes; then
 872 AC_CACHE_CHECK([for C11 _Noreturn feature], cf_cv_c11_noreturn,
 873         [AC_TRY_COMPILE([
 874 #include <stdio.h>
 875 #include <stdlib.h>
 876 #include <stdnoreturn.h>
 877 static _Noreturn void giveup(void) { exit(0); }
 878         ],
 879         [if (feof(stdin)) giveup()],
 880         cf_cv_c11_noreturn=yes,
 881         cf_cv_c11_noreturn=no)
 882         ])
 883 else
 884         cf_cv_c11_noreturn=no,
 885 fi
 886
 887 if test "$cf_cv_c11_noreturn" = yes; then
 888         AC_DEFINE(HAVE_STDNORETURN_H, 1,[Define if <stdnoreturn.h> header is available and working])
 889         AC_DEFINE_UNQUOTED(STDC_NORETURN,_Noreturn,[Define if C11 _Noreturn keyword is supported])
 890         HAVE_STDNORETURN_H=1
 891 else
 892         HAVE_STDNORETURN_H=0
 893 fi
 894
 895 AC_SUBST(HAVE_STDNORETURN_H)
 896 AC_SUBST(STDC_NORETURN)
 897 ])dnl
 898 dnl ---------------------------------------------------------------------------
 899 dnl CF_CC_ENV_FLAGS version: 10 updated: 2020/12/31 18:40:20
 900 dnl ---------------
 901 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 902 dnl into CC.  This will not help with broken scripts that wrap the compiler
 903 dnl with options, but eliminates a more common category of user confusion.
 904 dnl
 905 dnl In particular, it addresses the problem of being able to run the C
 906 dnl preprocessor in a consistent manner.
 907 dnl
 908 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 909 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 910 dnl outweighs that limitation.
 911 AC_DEFUN([CF_CC_ENV_FLAGS],
 912 [
 913 # This should have been defined by AC_PROG_CC
 914 : "${CC:=cc}"
 915
 916 AC_MSG_CHECKING(\$CFLAGS variable)
 917 case "x$CFLAGS" in
 918 (*-[[IUD]]*)
 919         AC_MSG_RESULT(broken)
 920         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 921         cf_flags="$CFLAGS"
 922         CFLAGS=
 923         for cf_arg in $cf_flags
 924         do
 925                 CF_ADD_CFLAGS($cf_arg)
 926         done
 927         ;;
 928 (*)
 929         AC_MSG_RESULT(ok)
 930         ;;
 931 esac
 932
 933 AC_MSG_CHECKING(\$CC variable)
 934 case "$CC" in
 935 (*[[\ \ ]]-*)
 936         AC_MSG_RESULT(broken)
 937         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 938         # humor him...
 939         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 940         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 941         CC="$cf_prog"
 942         for cf_arg in $cf_flags
 943         do
 944                 case "x$cf_arg" in
 945                 (x-[[IUDfgOW]]*)
 946                         CF_ADD_CFLAGS($cf_arg)
 947                         ;;
 948                 (*)
 949                         CC="$CC $cf_arg"
 950                         ;;
 951                 esac
 952         done
 953         CF_VERBOSE(resulting CC: '$CC')
 954         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 955         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 956         ;;
 957 (*)
 958         AC_MSG_RESULT(ok)
 959         ;;
 960 esac
 961 ])dnl
 962 dnl ---------------------------------------------------------------------------
 963 dnl CF_CFG_DEFAULTS version: 16 updated: 2021/01/04 19:33:05
 964 dnl ---------------
 965 dnl Determine the default configuration into which we'll install ncurses.  This
 966 dnl can be overridden by the user's command-line options.  There's two items to
 967 dnl look for:
 968 dnl     1. the prefix (e.g., /usr)
 969 dnl     2. the header files (e.g., /usr/include/ncurses)
 970 dnl We'll look for a previous installation of ncurses and use the same defaults.
 971 dnl
 972 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 973 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 974 dnl programs from a vendor's.
 975 AC_DEFUN([CF_CFG_DEFAULTS],
 976 [AC_REQUIRE([AC_PROG_FGREP])dnl
 977
 978 AC_MSG_CHECKING(for prefix)
 979 if test "x$prefix" = "xNONE" ; then
 980         case "$cf_cv_system_name" in
 981                 # non-vendor systems don't have a conflict
 982         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 983                 prefix=/usr
 984                 ;;
 985         (*)     prefix=$ac_default_prefix
 986                 ;;
 987         esac
 988 fi
 989 AC_MSG_RESULT($prefix)
 990
 991 if test "x$prefix" = "xNONE" ; then
 992 AC_MSG_CHECKING(for default include-directory)
 993 test -n "$verbose" && echo 1>&AC_FD_MSG
 994 for cf_symbol in \
 995         "$includedir" \
 996         "$includedir/ncurses" \
 997         "$prefix/include" \
 998         "$prefix/include/ncurses" \
 999         /usr/local/include \
1000         /usr/local/include/ncurses \
1001         /usr/include \
1002         /usr/include/ncurses
1003 do
1004         cf_dir=`eval echo "$cf_symbol"`
1005         if test -f "$cf_dir/curses.h" ; then
1006         if ( ${FGREP-fgrep} NCURSES_VERSION "$cf_dir/curses.h" >/dev/null 2>&1 ) ; then
1007                 includedir="$cf_symbol"
1008                 test -n "$verbose"  && echo $ECHO_N "   found " 1>&AC_FD_MSG
1009                 break
1010         fi
1011         fi
1012         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
1013 done
1014 AC_MSG_RESULT($includedir)
1015 fi
1016 ])dnl
1017 dnl ---------------------------------------------------------------------------
1018 dnl CF_CGETENT version: 6 updated: 2017/01/21 11:06:25
1019 dnl ----------
1020 dnl Check if the terminal-capability database functions are available.  If not,
1021 dnl ncurses has a much-reduced version.
1022 AC_DEFUN([CF_CGETENT],[
1023 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
1024 AC_TRY_LINK([
1025 #include <stdlib.h>],[
1026         char temp[128];
1027         char *buf = temp;
1028         char *db_array = temp;
1029         cgetent(&buf, &db_array, "vt100");
1030         cgetcap(buf, "tc", '=');
1031         cgetmatch(buf, "tc");
1032         ],
1033         [cf_cv_cgetent=yes],
1034         [cf_cv_cgetent=no])
1035 ])
1036
1037 if test "$cf_cv_cgetent" = yes
1038 then
1039         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
1040 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
1041 AC_TRY_LINK([
1042 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
1043 #include <stdlib.h>],[
1044         char temp[128];
1045         char *buf = temp;
1046 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
1047         const char *db_array = temp;
1048         cgetent(&buf, &db_array, "vt100");
1049 #endif
1050         cgetcap(buf, "tc", '=');
1051         cgetmatch(buf, "tc");
1052         ],
1053         [cf_cv_cgetent_const=yes],
1054         [cf_cv_cgetent_const=no])
1055 ])
1056         if test "$cf_cv_cgetent_const" = yes
1057         then
1058                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
1059         fi
1060 fi
1061 ])dnl
1062 dnl ---------------------------------------------------------------------------
1063 dnl CF_CHECK_CACHE version: 13 updated: 2020/12/31 10:54:15
1064 dnl --------------
1065 dnl Check if we're accidentally using a cache from a different machine.
1066 dnl Derive the system name, as a check for reusing the autoconf cache.
1067 dnl
1068 dnl If we've packaged config.guess and config.sub, run that (since it does a
1069 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
1070 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
1071 dnl which is useful in cross-compiles.
1072 dnl
1073 dnl Note: we would use $ac_config_sub, but that is one of the places where
1074 dnl autoconf 2.5x broke compatibility with autoconf 2.13
1075 AC_DEFUN([CF_CHECK_CACHE],
1076 [
1077 if test -f "$srcdir/config.guess" || test -f "$ac_aux_dir/config.guess" ; then
1078         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
1079         system_name="$host_os"
1080 else
1081         system_name="`(uname -s -r) 2>/dev/null`"
1082         if test -z "$system_name" ; then
1083                 system_name="`(hostname) 2>/dev/null`"
1084         fi
1085 fi
1086 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
1087 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
1088
1089 test -z "$system_name" && system_name="$cf_cv_system_name"
1090 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
1091
1092 if test ".$system_name" != ".$cf_cv_system_name" ; then
1093         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
1094         AC_MSG_ERROR("Please remove config.cache and try again.")
1095 fi
1096 ])dnl
1097 dnl ---------------------------------------------------------------------------
1098 dnl CF_CHECK_ENVIRON version: 4 updated: 2023/01/14 07:48:15
1099 dnl ----------------
1100 dnl Check for data that is usually declared in <unistd.h>, e.g., the 'environ'
1101 dnl variable.  Define a DECL_xxx symbol if we must declare it ourselves.
1102 dnl
1103 dnl $1 = the name to check
1104 dnl $2 = the assumed type
1105 AC_DEFUN([CF_CHECK_ENVIRON],
1106 [
1107 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1108     AC_TRY_COMPILE([
1109 #ifdef HAVE_STDLIB_H
1110 #include <stdlib.h>
1111 #endif
1112 #include <unistd.h> ],
1113     ifelse([$2],,void*,[$2]) x = (ifelse([$2],,void*,[$2])) $1; (void)x,
1114     [cf_cv_dcl_$1=yes],
1115     [cf_cv_dcl_$1=no])
1116 ])
1117
1118 if test "$cf_cv_dcl_$1" = no ; then
1119     CF_UPPER(cf_result,decl_$1)
1120     AC_DEFINE_UNQUOTED($cf_result)
1121 fi
1122
1123 # It's possible (for near-UNIX clones) that the data doesn't exist
1124 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1125 ])dnl
1126 dnl ---------------------------------------------------------------------------
1127 dnl CF_CHECK_ERRNO version: 13 updated: 2020/03/10 18:53:47
1128 dnl --------------
1129 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
1130 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
1131 dnl ourselves.
1132 dnl
1133 dnl $1 = the name to check
1134 dnl $2 = the assumed type
1135 AC_DEFUN([CF_CHECK_ERRNO],
1136 [
1137 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1138         AC_TRY_COMPILE([
1139 #ifdef HAVE_STDLIB_H
1140 #include <stdlib.h>
1141 #endif
1142 #include <stdio.h>
1143 #include <sys/types.h>
1144 #include <errno.h> ],
1145         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1; (void)x,
1146         [cf_cv_dcl_$1=yes],
1147         [cf_cv_dcl_$1=no])
1148 ])
1149
1150 if test "$cf_cv_dcl_$1" = no ; then
1151         CF_UPPER(cf_result,decl_$1)
1152         AC_DEFINE_UNQUOTED($cf_result)
1153 fi
1154
1155 # It's possible (for near-UNIX clones) that the data doesn't exist
1156 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1157 ])dnl
1158 dnl ---------------------------------------------------------------------------
1159 dnl CF_CHECK_EXTERN_DATA version: 5 updated: 2021/09/04 06:35:04
1160 dnl --------------------
1161 dnl Check for existence of external data in the current set of libraries.  If
1162 dnl we can modify it, it is real enough.
1163 dnl $1 = the name to check
1164 dnl $2 = its type
1165 AC_DEFUN([CF_CHECK_EXTERN_DATA],
1166 [
1167 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
1168         AC_TRY_LINK([
1169 #undef $1
1170 extern $2 $1;
1171 ],
1172         [$1 = 2],
1173         [cf_cv_have_$1=yes],
1174         [cf_cv_have_$1=no])
1175 ])
1176
1177 if test "$cf_cv_have_$1" = yes ; then
1178         CF_UPPER(cf_result,have_$1)
1179         AC_DEFINE_UNQUOTED($cf_result)
1180 fi
1181
1182 ])dnl
1183 dnl ---------------------------------------------------------------------------
1184 dnl CF_CHECK_FVISIBILITY version: 2 updated: 2020/04/04 16:16:13
1185 dnl --------------------
1186 dnl Check whether the compiler understands -fvisibility=hidden
1187 dnl
1188 dnl $1 = compiler
1189 dnl $2 = compiler-flags variable name
1190 dnl $3 = cache variable to set
1191 AC_DEFUN([CF_CHECK_FVISIBILITY],[
1192 AC_CACHE_CHECK(if $1 -fvisibility=hidden option works,$3,[
1193     cf_save_cflags="[$]$2"
1194     $2="[$]$2 -fvisibility=hidden"
1195     AC_TRY_LINK([
1196 __attribute__ ((visibility("default"))) int somefunc() {return 42;}
1197         ],[
1198         if (somefunc()) return 1;
1199 ],
1200     [$3=yes],
1201     [$3=no])
1202     $2=$cf_save_cflags
1203 ])
1204 ])dnl
1205 dnl ---------------------------------------------------------------------------
1206 dnl CF_CHECK_GETENV version: 3 updated: 2023/01/05 17:47:56
1207 dnl ---------------
1208 dnl Check if repeated getenv calls return the same pointer, e.g., it does not
1209 dnl discard the previous pointer when returning a new one.
1210 AC_DEFUN([CF_CHECK_GETENV],
1211 [
1212 AC_REQUIRE([CF_CHECK_ENVIRON])
1213 AC_CHECK_FUNC( getenv, ,, AC_MSG_ERROR(getenv not found) )
1214 AC_CHECK_FUNCS( putenv setenv strdup )
1215 AC_CACHE_CHECK(if getenv returns consistent values,cf_cv_consistent_getenv,[
1216 AC_TRY_RUN([
1217 $ac_includes_default
1218
1219 #if defined(HAVE_ENVIRON) && defined(DECL_ENVIRON) && !defined(environ)
1220 extern char **environ;  /* POSIX, but some systems are not... */
1221 #endif
1222
1223 #if defined(HAVE_STRDUP)
1224 #define str_alloc(s) strdup(s)
1225 #else
1226 #define str_alloc(s) strcpy(malloc(strlen(s) + 1, s))
1227 #endif
1228
1229 static void set_value(const char *name, const char *value)
1230 {
1231 #if defined(HAVE_SETENV)
1232         setenv(name, value, 1);
1233 #elif defined(HAVE_PUTENV)
1234         char buffer[1024];
1235         sprintf(buffer, "%s=%s", name, value);
1236         putenv(str_alloc(buffer));
1237 #else
1238 #error neither putenv/setenv found
1239 #endif
1240 }
1241 int main(void)
1242 {
1243         int pass;
1244         size_t numenv, limit, j;
1245         char **mynames;
1246         char **myvalues;
1247         char **mypointer;
1248         char *equals;
1249         for (numenv = 0; environ[numenv]; ++numenv) ;
1250         limit = numenv + 10;
1251         mynames = (char **) calloc(limit + 1, sizeof(char *));
1252         myvalues = (char **) calloc(limit + 1, sizeof(char *));
1253         mypointer = (char **) calloc(limit + 1, sizeof(char *));
1254 #if defined(HAVE_ENVIRON)
1255         for (j = 0; environ[j]; ++j) {
1256                 mynames[j] = str_alloc(environ[j]);
1257                 equals = strchr(mynames[j], '=');
1258                 if (equals != 0) {
1259                         *equals++ = '\\0';
1260                         myvalues[j] = str_alloc(equals);
1261                 } else {
1262                         myvalues[j] = str_alloc("");
1263                 }
1264         }
1265 #endif
1266         for (j = numenv; j < limit; ++j) {
1267                 char name[80];
1268                 char value[80];
1269                 size_t found;
1270                 size_t k = 0;
1271                 do {
1272                         size_t jk;
1273                         found = 0;
1274                         sprintf(name, "TERM%lu", (unsigned long) k);
1275                         for (jk = 0; jk < j; ++jk) {
1276                                 if (!strcmp(name, mynames[jk])) {
1277                                         found = 1;
1278                                         ++k;
1279                                         break;
1280                                 }
1281                         }
1282                 } while (found);
1283                 sprintf(value, "%lu:%p", (unsigned long) k, &mynames[j]);
1284                 set_value(name, value);
1285                 mynames[j] = str_alloc(name);
1286                 myvalues[j] = str_alloc(value);
1287         }
1288         for (pass = 0; pass < 3; ++pass) {
1289                 for (j = 0; j < limit; ++j) {
1290                         char *value = getenv(mynames[j]);
1291                         if (pass) {
1292                                 if (value == 0) {
1293                                         fprintf(stderr, "getenv returned null for %s\\n", mynames[j]);
1294                                         ${cf_cv_main_return:-return}(1);
1295                                 } else if (value != mypointer[j]) {
1296                                         fprintf(stderr, "getenv returned different pointer for %s\\n", mynames[j]);
1297                                         ${cf_cv_main_return:-return}(1);
1298                                 } else if (strcmp(value, myvalues[j])) {
1299                                         fprintf(stderr, "getenv returned different value for %s\\n", mynames[j]);
1300                                         ${cf_cv_main_return:-return}(1);
1301                                 }
1302                         } else {
1303                                 size_t k;
1304                                 mypointer[j] = value;
1305                                 for (k = 0; k < j; ++k) {
1306                                         if (mypointer[j] == mypointer[k]) {
1307                                                 fprintf(stderr, "getenv returned same pointer for %s and %s\\n", mynames[j], mynames[k]);
1308                                                 ${cf_cv_main_return:-return}(1);
1309                                         }
1310                                 }
1311                         }
1312                 }
1313         }
1314         ${cf_cv_main_return:-return}(0);
1315 }
1316 ],
1317 [cf_cv_consistent_getenv=yes],
1318 [cf_cv_consistent_getenv=no],
1319 [cf_cv_consistent_getenv=unknown])
1320 ])
1321
1322 if test "x$cf_cv_consistent_getenv" = xno
1323 then
1324         AC_DEFINE(HAVE_CONSISTENT_GETENV,1,[Define to 1 if getenv repeatably returns the same value for a given name])
1325 fi
1326 ])dnl
1327 dnl ---------------------------------------------------------------------------
1328 dnl CF_CHECK_GNAT_VERSION version: 4 updated: 2021/01/01 13:31:04
1329 dnl ---------------------
1330 AC_DEFUN([CF_CHECK_GNAT_VERSION],
1331 [
1332 AC_REQUIRE([CF_GNAT_VERSION])
1333 case "$cf_cv_gnat_version" in
1334 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
1335         cf_cv_prog_gnat_correct=yes
1336         ;;
1337 (*)
1338         AC_MSG_WARN(Unsupported GNAT version $cf_cv_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1339         cf_cv_prog_gnat_correct=no
1340         ;;
1341 esac
1342 ])
1343 dnl ---------------------------------------------------------------------------
1344 dnl CF_CHECK_GPM_WGETCH version: 6 updated: 2021/01/04 18:48:01
1345 dnl -------------------
1346 dnl Check if GPM is already linked with curses.  If so - and if the linkage
1347 dnl is not "weak" - warn about this because it can create problems linking
1348 dnl applications with ncurses.
1349 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
1350 AC_REQUIRE([AC_PROG_EGREP])dnl
1351
1352 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
1353
1354 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
1355 cf_cv_check_gpm_wgetch=unknown
1356 if test "$cross_compiling" != yes ; then
1357
1358 cat >conftest.$ac_ext <<CF_EOF
1359 #include <gpm.h>
1360 int main(void)
1361 {
1362         Gpm_Wgetch();
1363         ${cf_cv_main_return:-return}(0);
1364 }
1365 CF_EOF
1366
1367         cf_save_LIBS="$LIBS"
1368         # This only works if we can look at the symbol table.  If a shared
1369         # library is stripped for install, we cannot use that.  So we're forced
1370         # to rely on the static library, noting that some packagers may not
1371         # include it.
1372         LIBS="-static -lgpm -dynamic $LIBS"
1373         if AC_TRY_EVAL(ac_compile) ; then
1374                 if AC_TRY_EVAL(ac_link) ; then
1375                         cf_cv_check_gpm_wgetch="`nm \"conftest$ac_exeext\" | ${EGREP-egrep} '\<wgetch\>' | ${EGREP-egrep} '\<[[vVwW]]\>'`"
1376                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
1377                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
1378                 fi
1379         fi
1380         rm -rf ./conftest*
1381         LIBS="$cf_save_LIBS"
1382 fi
1383 ])
1384
1385 if test "$cf_cv_check_gpm_wgetch" != yes ; then
1386         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
1387 fi
1388 ])])dnl
1389 dnl ---------------------------------------------------------------------------
1390 dnl CF_CHECK_LIBSSP version: 1 updated: 2021/10/30 10:40:19
1391 dnl ---------------
1392 dnl Check if libssp is needed, e.g., to work around misconfigured libraries
1393 dnl used in cross-compiling to MinGW.
1394 AC_DEFUN([CF_CHECK_LIBSSP],[
1395 AC_CACHE_CHECK(if ssp library is needed,cf_cv_need_libssp,[
1396 AC_TRY_LINK([
1397 #include <sys/types.h>
1398 #include <dirent.h>
1399 ],[
1400        DIR *dp = opendir(".");
1401 ],cf_cv_need_libssp=no,[
1402         cf_save_LIBS="$LIBS"
1403         LIBS="$LIBS -lssp"
1404         AC_TRY_LINK([
1405 #include <sys/types.h>
1406 #include <dirent.h>
1407         ],[
1408                    DIR *dp = opendir(".");
1409         ],cf_cv_need_libssp=yes,
1410           cf_cv_need_libssp=maybe)
1411         LIBS="$cf_save_LIBS"
1412 ])dnl
1413 ])
1414
1415 if test "x$cf_cv_need_libssp" = xyes
1416 then
1417         CF_ADD_LIB(ssp)
1418 fi
1419 ])dnl
1420 dnl ---------------------------------------------------------------------------
1421 dnl CF_CHECK_LIBTOOL_VERSION version: 2 updated: 2021/05/01 16:24:34
1422 dnl ------------------------
1423 dnl Show the version of libtool
1424 dnl
1425 dnl Save the version in a cache variable - this is not entirely a good thing,
1426 dnl but the version string from libtool is very ugly, and for bug reports it
1427 dnl might be useful to have the original string.
1428 dnl
1429 dnl There is an imitation in OpenBSD, which has no apparent use other than to
1430 dnl deny that it is GNU libtool.  Just ignore it.
1431 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1432 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1433 then
1434         AC_MSG_CHECKING(version of $LIBTOOL)
1435         CF_LIBTOOL_VERSION
1436         AC_MSG_RESULT($cf_cv_libtool_version)
1437         if test -n "$cf_cv_libtool_version"
1438         then
1439                 cf_check_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' -e 's,[[()]],...,g' -e 's,[[ ]],-,g' -e '2,$d'`
1440                 case "x$cf_check_libtool_version" in
1441                 (*...GNU-libtool...*)
1442                         ;;
1443                 (*)
1444                         AC_MSG_ERROR(This is not GNU libtool)
1445                         ;;
1446                 esac
1447         else
1448                 AC_MSG_ERROR(No version found for $LIBTOOL)
1449         fi
1450 else
1451         AC_MSG_ERROR(GNU libtool has not been found)
1452 fi
1453 ])dnl
1454 dnl ---------------------------------------------------------------------------
1455 dnl CF_CHECK_WCHAR_H version: 3 updated: 2021/01/01 13:31:04
1456 dnl ----------------
1457 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1458 AC_DEFUN([CF_CHECK_WCHAR_H],[
1459 AC_CHECK_HEADERS( \
1460 wchar.h \
1461 wctype.h \
1462 )
1463 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1464 AC_TRY_COMPILE(
1465 [
1466 #include <stdlib.h>
1467 #ifdef HAVE_WCHAR_H
1468 #include <wchar.h>
1469 #endif
1470 #ifdef HAVE_WCTYPE_H
1471 #include <wctype.h>
1472 #endif
1473 ],[
1474         wint_t foo = 0;
1475         int bar = iswpunct(foo)],
1476         [cf_cv_wchar_h_okay=yes],
1477         [cf_cv_wchar_h_okay=no])])
1478
1479 if test "$cf_cv_wchar_h_okay" = no
1480 then
1481         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1482 fi
1483 ])dnl
1484 dnl ---------------------------------------------------------------------------
1485 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 3 updated: 2023/01/05 18:01:30
1486 dnl -------------------------
1487 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1488 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1489 dnl
1490 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1491 dnl all of those were combined into a page of useful graphics characters.
1492 dnl
1493 dnl So far, so good.
1494 dnl
1495 dnl However, while they are useful, there are other considerations.  CJK
1496 dnl is (because of poor device resolution) often rendered as double-width
1497 dnl characters.  So... for these generally-useful characters, what should
1498 dnl be the width (to make them consistent with adjacent characters)?
1499 dnl
1500 dnl The obvious choice would have been to make this locale-dependent, and use
1501 dnl wcwidth() to tell applications what the actual width is.  That was too
1502 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1503 dnl See for example
1504 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1505 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1506 dnl
1507 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1508 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1509 dnl instance, it lists half (44/96) of the Latin-1 characters as
1510 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1511 dnl
1512 dnl What this means for the implementor is that on some systems wcwidth() can
1513 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1514 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1515 dnl characters).  These do not necessarily match the behavior of the terminal
1516 dnl emulator.  xterm, for instance, does an optional startup check to find if
1517 dnl this problem (or similar) exists with the system's locale tables, rejecting
1518 dnl them if they are too unreliable.
1519 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1520 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1521 cat >conftest.in <<CF_EOF
1522 -       VT100 symbols
1523 0x250c  upper left corner
1524 0x2514  lower left corner
1525 0x2510  upper right corner
1526 0x2518  lower right corner
1527 0x251c  tee pointing left
1528 0x2524  tee pointing right
1529 0x2534  tee pointing up
1530 0x252c  tee pointing down
1531 0x2500  horizontal line
1532 0x2502  vertical line
1533 0x253c  large plus or crossover
1534 0x23ba  scan line 1
1535 0x23bd  scan line 9
1536 0x25c6  diamond
1537 0x2592  checker board (stipple)
1538 0x00b0  degree symbol
1539 0x00b1  plus/minus
1540 0x00b7  bullet
1541 -       Teletype 5410v1 symbols
1542 0x2190  arrow pointing left
1543 0x2192  arrow pointing right
1544 0x2193  arrow pointing down
1545 0x2191  arrow pointing up
1546 0x2592  board of squares
1547 0x2603  lantern symbol
1548 0x25ae  solid square block
1549 -       these defaults were invented for ncurses
1550 0x23bb  scan line 3
1551 0x23bc  scan line 7
1552 0x2264  less-than-or-equal-to
1553 0x2265  greater-than-or-equal-to
1554 0x03c0  greek pi
1555 0x2260  not-equal
1556 0x00a3  pound-sterling symbol
1557 -       thick-line-drawing
1558 0x250f  upper left corner
1559 0x2517  lower left corner
1560 0x2513  upper right corner
1561 0x251b  lower right corner
1562 0x2523  tee pointing left
1563 0x252b  tee pointing right
1564 0x253b  tee pointing up
1565 0x2533  tee pointing down
1566 0x2501  horizontal line
1567 0x2503  vertical line
1568 0x254b  large plus or crossover
1569 -       double-line-drawing
1570 0x2554  upper left corner
1571 0x255a  lower left corner
1572 0x2557  upper right corner
1573 0x255d  lower right corner
1574 0x2563  tee pointing left
1575 0x2560  tee pointing right
1576 0x2569  tee pointing up
1577 0x2566  tee pointing down
1578 0x2550  horizontal line
1579 0x2551  vertical line
1580 0x256c  large plus or crossover
1581 CF_EOF
1582 AC_TRY_RUN([
1583 $ac_includes_default
1584
1585 #include <locale.h>
1586 #include <wchar.h>
1587
1588 #define MY_LEN 80
1589
1590 int
1591 main(void)
1592 {
1593         FILE *fp;
1594         int value;
1595         char buffer[MY_LEN + 1];
1596         char notes[MY_LEN + 1];
1597         int totals = 0;
1598         int passed = 0;
1599
1600         if (setlocale(LC_ALL, "en_US.UTF8") ||
1601                 setlocale(LC_ALL, "en_US.UTF-8") ||
1602                 setlocale(LC_ALL, "en_US.utf8") ||
1603                 setlocale(LC_ALL, "en_US.utf-8")) {
1604                 if ((fp = fopen("conftest.in", "r")) != 0) {
1605                         while (fgets(buffer, MY_LEN, fp) != 0) {
1606                                 if (*buffer == '-') {
1607                                         fprintf(stderr, "\\t%s", buffer);
1608                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1609                                         ++totals;
1610                                         if (wcwidth(value) == 1)
1611                                                 ++passed;
1612                                         fprintf(stderr, "%d\\t%s", wcwidth(value), buffer);
1613                                 } else {
1614                                         fprintf(stderr, "?\\t%s", buffer);
1615                                 }
1616                         }
1617                 }
1618         }
1619         fprintf(stderr, "%d/%d passed wcwidth/graphics check\\n", passed, totals);
1620         return (totals == passed) ? 0 : 1;
1621 }
1622 ],
1623 [cf_cv_wcwidth_graphics=yes],
1624 [cf_cv_wcwidth_graphics=no],
1625 [cf_cv_wcwidth_graphics=unknown])
1626 ])
1627 ])dnl
1628 dnl ---------------------------------------------------------------------------
1629 dnl CF_CLANG_COMPILER version: 8 updated: 2021/01/01 13:31:04
1630 dnl -----------------
1631 dnl Check if the given compiler is really clang.  clang's C driver defines
1632 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1633 dnl not ignore some gcc options.
1634 dnl
1635 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1636 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1637 dnl the wrappers for gcc and g++ warnings.
1638 dnl
1639 dnl $1 = GCC (default) or GXX
1640 dnl $2 = CLANG_COMPILER (default)
1641 dnl $3 = CFLAGS (default) or CXXFLAGS
1642 AC_DEFUN([CF_CLANG_COMPILER],[
1643 ifelse([$2],,CLANG_COMPILER,[$2])=no
1644
1645 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1646         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1647         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1648         AC_TRY_COMPILE([],[
1649 #ifdef __clang__
1650 #else
1651 make an error
1652 #endif
1653 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1654 ],[])
1655         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1656         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1657 fi
1658
1659 CLANG_VERSION=none
1660
1661 if test "x$ifelse([$2],,CLANG_COMPILER,[$2])" = "xyes" ; then
1662         case "$CC" in
1663         (c[[1-9]][[0-9]]|*/c[[1-9]][[0-9]])
1664                 AC_MSG_WARN(replacing broken compiler alias $CC)
1665                 CFLAGS="$CFLAGS -std=`echo "$CC" | sed -e 's%.*/%%'`"
1666                 CC=clang
1667                 ;;
1668         esac
1669
1670         AC_MSG_CHECKING(version of $CC)
1671         CLANG_VERSION="`$CC --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(CLANG[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1672         test -z "$CLANG_VERSION" && CLANG_VERSION=unknown
1673         AC_MSG_RESULT($CLANG_VERSION)
1674
1675         for cf_clang_opt in \
1676                 -Qunused-arguments \
1677                 -Wno-error=implicit-function-declaration
1678         do
1679                 AC_MSG_CHECKING(if option $cf_clang_opt works)
1680                 cf_save_CFLAGS="$CFLAGS"
1681                 CFLAGS="$CFLAGS $cf_clang_opt"
1682                 AC_TRY_LINK([
1683                         #include <stdio.h>],[
1684                         printf("hello!\\n");],[
1685                         cf_clang_optok=yes],[
1686                         cf_clang_optok=no])
1687                 AC_MSG_RESULT($cf_clang_optok)
1688                 CFLAGS="$cf_save_CFLAGS"
1689                 if test "$cf_clang_optok" = yes; then
1690                         CF_VERBOSE(adding option $cf_clang_opt)
1691                         CF_APPEND_TEXT(CFLAGS,$cf_clang_opt)
1692                 fi
1693         done
1694 fi
1695 ])
1696 dnl ---------------------------------------------------------------------------
1697 dnl CF_CONST_X_STRING version: 7 updated: 2021/06/07 17:39:17
1698 dnl -----------------
1699 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
1700 dnl character-strings.
1701 dnl
1702 dnl It is ambiguous because the specification accommodated the pre-ANSI
1703 dnl compilers bundled by more than one vendor in lieu of providing a standard C
1704 dnl compiler other than by costly add-ons.  Because of this, the specification
1705 dnl did not take into account the use of const for telling the compiler that
1706 dnl string literals would be in readonly memory.
1707 dnl
1708 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
1709 dnl let the compiler decide how to represent Xt's strings which were #define'd.
1710 dnl That does not solve the problem of using the block of Xt's strings which
1711 dnl are compiled into the library (and is less efficient than one might want).
1712 dnl
1713 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
1714 dnl when compiling the library and compiling using the library, to tell the
1715 dnl compiler that String is const.
1716 AC_DEFUN([CF_CONST_X_STRING],
1717 [
1718 AC_REQUIRE([AC_PATH_XTRA])
1719
1720 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
1721
1722 AC_TRY_COMPILE(
1723 [
1724 #include <stdlib.h>
1725 #include <X11/Intrinsic.h>
1726 ],
1727 [String foo = malloc(1); free((void*)foo)],[
1728
1729 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
1730         AC_TRY_COMPILE(
1731                 [
1732 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
1733 #undef  XTSTRINGDEFINES /* X11R5 and later */
1734 #include <stdlib.h>
1735 #include <X11/Intrinsic.h>
1736                 ],[String foo = malloc(1); *foo = 0],[
1737                         cf_cv_const_x_string=no
1738                 ],[
1739                         cf_cv_const_x_string=yes
1740                 ])
1741 ])
1742
1743 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
1744
1745 case "$cf_cv_const_x_string" in
1746 (no)
1747         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
1748         ;;
1749 (*)
1750         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
1751         ;;
1752 esac
1753
1754 ])
1755 ])dnl
1756 dnl ---------------------------------------------------------------------------
1757 dnl CF_CPP_OVERRIDE version: 1 updated: 2022/08/20 16:07:10
1758 dnl ---------------
1759 dnl Check if the C++ compiler accepts the override keyword.  This is a C++-11
1760 dnl feature.
1761 AC_DEFUN([CF_CPP_OVERRIDE],
1762 [
1763 if test -n "$CXX"; then
1764 AC_CACHE_CHECK(if $CXX accepts override keyword,cf_cv_cpp_override,[
1765         AC_LANG_SAVE
1766         AC_LANG_CPLUSPLUS
1767         AC_TRY_RUN([
1768
1769 class base
1770 {
1771 public:
1772         virtual int foo(float x) = 0;
1773 };
1774
1775
1776 class derived: public base
1777 {
1778 public:
1779         int foo(float x) override { return x != 0.0 ? 1 : 0; }
1780 };
1781
1782 int main(void) { }
1783 ],
1784         [cf_cv_cpp_override=yes],
1785         [cf_cv_cpp_override=no],
1786         [cf_cv_cpp_override=unknown])
1787         AC_LANG_RESTORE
1788 ])
1789 fi
1790 test "$cf_cv_cpp_override" = yes && AC_DEFINE(CPP_HAS_OVERRIDE,1,[Define to 1 if C++ has override keyword])
1791 ])dnl
1792 dnl ---------------------------------------------------------------------------
1793 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1794 dnl -----------------
1795 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1796 dnl is a late feature for the standard and is not in some recent compilers
1797 dnl (1999/9/11).
1798 AC_DEFUN([CF_CPP_PARAM_INIT],
1799 [
1800 if test -n "$CXX"; then
1801 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1802         AC_LANG_SAVE
1803         AC_LANG_CPLUSPLUS
1804         AC_TRY_RUN([
1805 class TEST {
1806 private:
1807         int value;
1808 public:
1809         TEST(int x = 1);
1810         ~TEST();
1811 };
1812
1813 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1814 {
1815         value = x;
1816 }
1817 int main(void) { }
1818 ],
1819         [cf_cv_cpp_param_init=yes],
1820         [cf_cv_cpp_param_init=no],
1821         [cf_cv_cpp_param_init=unknown])
1822         AC_LANG_RESTORE
1823 ])
1824 fi
1825 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1826 ])dnl
1827 dnl ---------------------------------------------------------------------------
1828 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1829 dnl ------------------
1830 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1831 dnl not be supported in g++ before 3.0
1832 AC_DEFUN([CF_CPP_STATIC_CAST],
1833 [
1834 if test -n "$CXX"; then
1835
1836 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1837         AC_LANG_SAVE
1838         AC_LANG_CPLUSPLUS
1839
1840         AC_TRY_COMPILE([
1841 class NCursesPanel
1842 {
1843 public:
1844   NCursesPanel(int nlines,
1845                int ncols,
1846                int begin_y = 0,
1847                int begin_x = 0)
1848   {
1849   }
1850   NCursesPanel();
1851   ~NCursesPanel();
1852 };
1853
1854 template<class T> class NCursesUserPanel : public NCursesPanel
1855 {
1856 public:
1857   NCursesUserPanel (int nlines,
1858                     int ncols,
1859                     int begin_y = 0,
1860                     int begin_x = 0,
1861                     const T* p_UserData = static_cast<T*>(0))
1862     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1863   {
1864   };
1865   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1866   {
1867   };
1868
1869   virtual ~NCursesUserPanel() {};
1870 };
1871 ],[
1872         const char* p_UserData = static_cast<char*>(0)],
1873         [cf_cv_cpp_static_cast=yes],
1874         [cf_cv_cpp_static_cast=no])
1875
1876         AC_LANG_RESTORE
1877 ])
1878
1879 fi
1880
1881 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1882 ])dnl
1883 dnl ---------------------------------------------------------------------------
1884 dnl CF_CXX_AR_FLAGS version: 3 updated: 2021/01/01 13:31:04
1885 dnl ---------------
1886 dnl Setup special archiver flags for given compilers.
1887 AC_DEFUN([CF_CXX_AR_FLAGS],[
1888         CXX_AR='$(AR)'
1889         CXX_ARFLAGS='$(ARFLAGS)'
1890         case "$cf_cv_system_name" in
1891         (irix*)
1892             if test "$GXX" != yes ; then
1893                 CXX_AR='$(CXX)'
1894                 CXX_ARFLAGS='-ar -o'
1895             fi
1896             ;;
1897         (sco3.2v5*)
1898             CXXLDFLAGS="-u main"
1899             ;;
1900         (solaris2*)
1901             if test "$GXX" != yes ; then
1902                 CXX_AR='$(CXX)'
1903                 CXX_ARFLAGS='-xar -o'
1904             fi
1905             ;;
1906         esac
1907         AC_SUBST(CXXLDFLAGS)
1908         AC_SUBST(CXX_AR)
1909         AC_SUBST(CXX_ARFLAGS)
1910 ])dnl
1911 dnl ---------------------------------------------------------------------------
1912 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1913 dnl -------------------------
1914 dnl For c++, check if iostream uses "std::" namespace.
1915 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1916 AC_CHECK_HEADERS(iostream)
1917 if test x"$ac_cv_header_iostream" = xyes ; then
1918         AC_MSG_CHECKING(if iostream uses std-namespace)
1919         AC_TRY_COMPILE([
1920 #include <iostream>
1921 using std::endl;
1922 using std::cerr;],[
1923 cerr << "testing" << endl;
1924 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1925         AC_MSG_RESULT($cf_iostream_namespace)
1926         if test "$cf_iostream_namespace" = yes ; then
1927                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1928         fi
1929 fi
1930 ])dnl
1931 dnl ---------------------------------------------------------------------------
1932 dnl CF_C_INLINE version: 6 updated: 2019/09/07 13:38:36
1933 dnl -----------
1934 dnl Check if the C compiler supports "inline".
1935 dnl $1 is the name of a shell variable to set if inline is supported
1936 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1937 AC_DEFUN([CF_C_INLINE],[
1938 AC_REQUIRE([CF_GCC_VERSION])
1939 AC_C_INLINE
1940 $1=
1941 if test "$ac_cv_c_inline" != no ; then
1942         $1=inline
1943         if test "$INTEL_COMPILER" = yes
1944         then
1945                 :
1946         elif test "$CLANG_COMPILER" = yes
1947         then
1948                 :
1949         elif test "$GCC" = yes
1950         then
1951                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1952                 cf_save_CFLAGS=$CFLAGS
1953                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1954                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1955                 [${cf_cv_main_return:-return} foo()],
1956                 [cf_cv_gcc_inline=yes],
1957                 [cf_cv_gcc_inline=no])
1958                 CFLAGS=$cf_save_CFLAGS
1959                 ])
1960                 if test "$cf_cv_gcc_inline" = yes ; then
1961                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1962                 fi
1963         fi
1964 fi
1965 AC_SUBST($1)
1966 ])dnl
1967 dnl ---------------------------------------------------------------------------
1968 dnl CF_DIRNAME version: 5 updated: 2020/12/31 20:19:42
1969 dnl ----------
1970 dnl "dirname" is not portable, so we fake it with a shell script.
1971 AC_DEFUN([CF_DIRNAME],[$1=`echo "$2" | sed -e 's%/[[^/]]*$%%'`])dnl
1972 dnl ---------------------------------------------------------------------------
1973 dnl CF_DIRS_TO_MAKE version: 4 updated: 2021/01/01 13:31:04
1974 dnl ---------------
1975 AC_DEFUN([CF_DIRS_TO_MAKE],
1976 [
1977 DIRS_TO_MAKE="lib"
1978 for cf_item in $cf_list_models
1979 do
1980         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1981         for cf_item2 in $DIRS_TO_MAKE
1982         do
1983                 test "$cf_item2" = "$cf_subdir" && break
1984         done
1985         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1986 done
1987 for cf_dir in $DIRS_TO_MAKE
1988 do
1989         test ! -d "$cf_dir" && mkdir "$cf_dir"
1990 done
1991 AC_SUBST(DIRS_TO_MAKE)
1992 ])dnl
1993 dnl ---------------------------------------------------------------------------
1994 dnl CF_DISABLE_ECHO version: 14 updated: 2021/09/04 06:35:04
1995 dnl ---------------
1996 dnl You can always use "make -n" to see the actual options, but it is hard to
1997 dnl pick out/analyze warning messages when the compile-line is long.
1998 dnl
1999 dnl Sets:
2000 dnl     ECHO_LT - symbol to control if libtool is verbose
2001 dnl     ECHO_LD - symbol to prefix "cc -o" lines
2002 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
2003 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
2004 dnl     ECHO_CC - symbol to put before any "cc" line
2005 dnl
2006 AC_DEFUN([CF_DISABLE_ECHO],[
2007 AC_MSG_CHECKING(if you want to see long compiling messages)
2008 CF_ARG_DISABLE(echo,
2009         [  --disable-echo          do not display "compiling" commands],
2010         [
2011         ECHO_LT='--silent'
2012         ECHO_LD='@echo linking [$]@;'
2013         RULE_CC='@echo compiling [$]<'
2014         SHOW_CC='@echo compiling [$]@'
2015         ECHO_CC='@'
2016 ],[
2017         ECHO_LT=''
2018         ECHO_LD=''
2019         RULE_CC=''
2020         SHOW_CC=''
2021         ECHO_CC=''
2022 ])
2023 AC_MSG_RESULT($enableval)
2024 AC_SUBST(ECHO_LT)
2025 AC_SUBST(ECHO_LD)
2026 AC_SUBST(RULE_CC)
2027 AC_SUBST(SHOW_CC)
2028 AC_SUBST(ECHO_CC)
2029 ])dnl
2030 dnl ---------------------------------------------------------------------------
2031 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
2032 dnl ------------------------
2033 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
2034 AC_MSG_CHECKING(if we want to use GNAT projects)
2035 CF_ARG_DISABLE(gnat-projects,
2036         [  --disable-gnat-projects test: disable GNAT projects even if usable],
2037         [enable_gnat_projects=no],
2038         [enable_gnat_projects=yes])
2039 AC_MSG_RESULT($enable_gnat_projects)
2040 ])dnl
2041 dnl ---------------------------------------------------------------------------
2042 dnl CF_DISABLE_LEAKS version: 9 updated: 2021/04/03 16:41:50
2043 dnl ----------------
2044 dnl Combine no-leak checks with the libraries or tools that are used for the
2045 dnl checks.
2046 AC_DEFUN([CF_DISABLE_LEAKS],[
2047
2048 AC_REQUIRE([CF_WITH_DMALLOC])
2049 AC_REQUIRE([CF_WITH_DBMALLOC])
2050 AC_REQUIRE([CF_WITH_VALGRIND])
2051
2052 AC_MSG_CHECKING(if you want to perform memory-leak testing)
2053 AC_ARG_ENABLE(leaks,
2054         [  --disable-leaks         test: free permanent memory, analyze leaks],
2055         [enable_leaks=$enableval],
2056         [enable_leaks=yes])
2057 dnl with_no_leaks is more readable...
2058 if test "x$enable_leaks" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi
2059 AC_MSG_RESULT($with_no_leaks)
2060
2061 if test "$enable_leaks" = no ; then
2062         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
2063         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
2064 fi
2065 ])dnl
2066 dnl ---------------------------------------------------------------------------
2067 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
2068 dnl --------------------------
2069 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
2070 dnl the older "-version-info" feature.  The newer feature allows us to use
2071 dnl version numbering on shared libraries which make them compatible with
2072 dnl various systems.
2073 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
2074 [
2075 AC_MSG_CHECKING(if libtool -version-number should be used)
2076 CF_ARG_DISABLE(libtool-version,
2077         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
2078         [cf_libtool_version=no],
2079         [cf_libtool_version=yes])
2080 AC_MSG_RESULT($cf_libtool_version)
2081
2082 if test "$cf_libtool_version" = yes ; then
2083         LIBTOOL_VERSION="-version-number"
2084 else
2085         LIBTOOL_VERSION="-version-info"
2086         case "x$VERSION" in
2087         (x)
2088                 AC_MSG_WARN(VERSION was not set)
2089                 ;;
2090         (x*.*.*)
2091                 ABI_VERSION="$VERSION"
2092                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
2093                 ;;
2094         (x*:*:*)
2095                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
2096                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
2097                 ;;
2098         (*)
2099                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
2100                 ;;
2101         esac
2102 fi
2103
2104 AC_SUBST(ABI_VERSION)
2105 AC_SUBST(LIBTOOL_VERSION)
2106 ])dnl
2107 dnl ---------------------------------------------------------------------------
2108 dnl CF_DISABLE_RPATH_HACK version: 3 updated: 2021/01/05 20:14:44
2109 dnl ---------------------
2110 dnl The rpath-hack makes it simpler to build programs, particularly with the
2111 dnl *BSD ports which may have essential libraries in unusual places.  But it
2112 dnl can interfere with building an executable for the base system.  Use this
2113 dnl option in that case.
2114 AC_DEFUN([CF_DISABLE_RPATH_HACK],
2115 [
2116 AC_MSG_CHECKING(if rpath-hack should be disabled)
2117 CF_ARG_DISABLE(rpath-hack,
2118         [  --disable-rpath-hack    don't add rpath options for additional libraries],
2119         [enable_rpath_hack=no],
2120         [enable_rpath_hack=yes])
2121 dnl TODO - drop cf_disable_rpath_hack
2122 if test "x$enable_rpath_hack" = xno; then cf_disable_rpath_hack=yes; else cf_disable_rpath_hack=no; fi
2123 AC_MSG_RESULT($cf_disable_rpath_hack)
2124
2125 if test "$enable_rpath_hack" = yes ; then
2126         CF_RPATH_HACK
2127 fi
2128 ])
2129 dnl ---------------------------------------------------------------------------
2130 dnl CF_ENABLE_BROKEN_LINKER version: 2 updated: 2021/01/02 17:09:14
2131 dnl -----------------------
2132 dnl Some linkers cannot reference a data-only object.  Cygwin used to be one.
2133 dnl This usually follows CF_LINK_DATAONLY, but is not required in case we need
2134 dnl an unconditional feature.
2135 AC_DEFUN([CF_ENABLE_BROKEN_LINKER],[
2136
2137 AC_MSG_CHECKING(if you want broken-linker support code)
2138 AC_ARG_ENABLE(broken_linker,
2139         [  --enable-broken_linker  compile with broken-linker support code],
2140         [with_broken_linker=$enableval],
2141         [with_broken_linker=no])
2142 AC_MSG_RESULT($with_broken_linker)
2143
2144 : "${BROKEN_LINKER:=0}"
2145 if test "x$with_broken_linker" = xyes ; then
2146         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
2147         BROKEN_LINKER=1
2148 fi
2149 AC_SUBST(BROKEN_LINKER)
2150 ])dnl
2151 dnl ---------------------------------------------------------------------------
2152 dnl CF_ENABLE_PC_FILES version: 16 updated: 2021/11/20 12:48:37
2153 dnl ------------------
2154 dnl This is the "--enable-pc-files" option, which is available if there is a
2155 dnl pkg-config configuration on the local machine.
2156 AC_DEFUN([CF_ENABLE_PC_FILES],[
2157 AC_REQUIRE([CF_PKG_CONFIG])
2158 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
2159
2160 if test "x$PKG_CONFIG" != xnone
2161 then
2162         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
2163 else
2164         AC_MSG_CHECKING(if we should install .pc files)
2165 fi
2166
2167 AC_ARG_ENABLE(pc-files,
2168         [  --enable-pc-files       generate and install .pc files for pkg-config],
2169         [enable_pc_files=$enableval],
2170         [enable_pc_files=no])
2171 AC_MSG_RESULT($enable_pc_files)
2172
2173 if test "x$enable_pc_files" != xno
2174 then
2175         MAKE_PC_FILES=
2176         case "x$PKG_CONFIG_LIBDIR" in
2177         (xno|xnone|xyes|x)
2178                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
2179                 ;;
2180         (*)
2181                 cf_pkg_config_libdir="$PKG_CONFIG_LIBDIR"
2182                 CF_PATH_SYNTAX(cf_pkg_config_libdir)
2183                 ;;
2184         esac
2185 else
2186         MAKE_PC_FILES="#"
2187 fi
2188 AC_SUBST(MAKE_PC_FILES)
2189 ])dnl
2190 dnl ---------------------------------------------------------------------------
2191 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
2192 dnl ---------------
2193 dnl Check if the rpath option should be used, setting cache variable
2194 dnl cf_cv_enable_rpath if so.
2195 AC_DEFUN([CF_ENABLE_RPATH],
2196 [
2197 AC_MSG_CHECKING(if rpath option should be used)
2198 AC_ARG_ENABLE(rpath,
2199 [  --enable-rpath          use rpath option when generating shared libraries],
2200 [cf_cv_enable_rpath=$enableval],
2201 [cf_cv_enable_rpath=no])
2202 AC_MSG_RESULT($cf_cv_enable_rpath)
2203 ])dnl
2204 dnl ---------------------------------------------------------------------------
2205 dnl CF_ENABLE_STRING_HACKS version: 6 updated: 2021/01/05 19:23:48
2206 dnl ----------------------
2207 dnl On a few platforms, the compiler and/or loader nags with untruthful
2208 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
2209 dnl and implying that most uses of the recommended alternatives are correct.
2210 dnl
2211 dnl Factually speaking, no one has actually counted the number of uses of these
2212 dnl functions versus the total of incorrect uses.  Samples of a few thousand
2213 dnl instances are meaningless compared to the hundreds of millions of lines of
2214 dnl existing C code.
2215 dnl
2216 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
2217 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
2218 dnl standard - but evolved through phases, and older implementations are likely
2219 dnl to yield surprising results, as documented in manpages on various systems.
2220 AC_DEFUN([CF_ENABLE_STRING_HACKS],
2221 [
2222 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
2223 AC_ARG_ENABLE(string-hacks,
2224         [  --enable-string-hacks   work around bogus compiler/loader warnings],
2225         [enable_string_hacks=$enableval],
2226         [enable_string_hacks=no])
2227 AC_MSG_RESULT($enable_string_hacks)
2228
2229 if test "x$enable_string_hacks" = "xyes"; then
2230         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
2231         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
2232         AC_CHECK_FUNC(strlcat,[
2233                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2234                 ],[
2235                 AC_CHECK_LIB(bsd,strlcat,[
2236                         CF_ADD_LIB(bsd)
2237                         AC_CHECK_HEADERS(bsd/string.h)
2238                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2239                         ])
2240                 ])
2241         AC_CHECK_FUNCS( strlcpy snprintf )
2242 fi
2243 ])dnl
2244 dnl ---------------------------------------------------------------------------
2245 dnl CF_ENABLE_WARNINGS version: 9 updated: 2021/01/05 19:40:50
2246 dnl ------------------
2247 dnl Configure-option to enable gcc warnings
2248 dnl
2249 dnl $1 = extra options to add, if supported
2250 dnl $2 = option for checking attributes.  By default, this is done when
2251 dnl      warnings are enabled.  For other values:
2252 dnl      yes: always do this, e.g., to use in generated library-headers
2253 dnl      no: never do this
2254 AC_DEFUN([CF_ENABLE_WARNINGS],[
2255 if test "$GCC" = yes || test "$GXX" = yes
2256 then
2257 CF_FIX_WARNINGS(CFLAGS)
2258 CF_FIX_WARNINGS(CPPFLAGS)
2259 CF_FIX_WARNINGS(LDFLAGS)
2260 AC_MSG_CHECKING(if you want to turn on gcc warnings)
2261 CF_ARG_ENABLE(warnings,
2262         [  --enable-warnings       test: turn on gcc compiler warnings],
2263         [enable_warnings=yes],
2264         [enable_warnings=no])
2265 AC_MSG_RESULT($enable_warnings)
2266 if test "$enable_warnings" = "yes"
2267 then
2268         ifelse($2,,[CF_GCC_ATTRIBUTES])
2269         CF_GCC_WARNINGS($1)
2270 fi
2271 ifelse($2,yes,[CF_GCC_ATTRIBUTES])
2272 fi
2273 ])dnl
2274 dnl ---------------------------------------------------------------------------
2275 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
2276 dnl --------
2277 dnl Check if 'errno' is declared in <errno.h>
2278 AC_DEFUN([CF_ERRNO],
2279 [
2280 CF_CHECK_ERRNO(errno)
2281 ])dnl
2282 dnl ---------------------------------------------------------------------------
2283 dnl CF_ETIP_DEFINES version: 6 updated: 2021/01/02 17:09:14
2284 dnl ---------------
2285 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
2286 dnl math.h and builtin.h, only for ncurses
2287 AC_DEFUN([CF_ETIP_DEFINES],
2288 [
2289 AC_MSG_CHECKING(for special defines needed for etip.h)
2290 cf_save_CXXFLAGS="$CXXFLAGS"
2291 cf_result="none"
2292
2293 # etip.h includes ncurses.h which includes ncurses_dll.h
2294 # But ncurses_dll.h is generated - fix here.
2295 test -d include || mkdir include
2296 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' "${srcdir}/include/ncurses_dll.h.in" >include/ncurses_dll.h
2297
2298 for cf_math in "" MATH_H
2299 do
2300 for cf_excp in "" MATH_EXCEPTION
2301 do
2302         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
2303         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
2304         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
2305 AC_TRY_COMPILE([
2306 #include <etip.h.in>
2307 ],[],[
2308         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
2309         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
2310         cf_result="$cf_math $cf_excp"
2311         break 2
2312 ],[])
2313 done
2314 done
2315 AC_MSG_RESULT($cf_result)
2316 CXXFLAGS="$cf_save_CXXFLAGS"
2317 ])
2318 dnl ---------------------------------------------------------------------------
2319 dnl CF_FIND_LINKAGE version: 22 updated: 2020/12/31 20:19:42
2320 dnl ---------------
2321 dnl Find a library (specifically the linkage used in the code fragment),
2322 dnl searching for it if it is not already in the library path.
2323 dnl See also CF_ADD_SEARCHPATH.
2324 dnl
2325 dnl Parameters (4-on are optional):
2326 dnl     $1 = headers for library entrypoint
2327 dnl     $2 = code fragment for library entrypoint
2328 dnl     $3 = the library name without the "-l" option or ".so" suffix.
2329 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
2330 dnl     $5 = action to perform if not successful
2331 dnl     $6 = module name, if not the same as the library name
2332 dnl     $7 = extra libraries
2333 dnl
2334 dnl Sets these variables:
2335 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
2336 dnl     $cf_cv_header_path_$3 - include-directory if needed
2337 dnl     $cf_cv_library_path_$3 - library-directory if needed
2338 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
2339 AC_DEFUN([CF_FIND_LINKAGE],[
2340
2341 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
2342 # will be set on completion of the AC_TRY_LINK below.
2343 cf_cv_header_path_$3=
2344 cf_cv_library_path_$3=
2345
2346 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
2347
2348 cf_save_LIBS="$LIBS"
2349
2350 AC_TRY_LINK([$1],[$2],[
2351         cf_cv_find_linkage_$3=yes
2352         cf_cv_header_path_$3=/usr/include
2353         cf_cv_library_path_$3=/usr/lib
2354 ],[
2355
2356 LIBS="-l$3 $7 $cf_save_LIBS"
2357
2358 AC_TRY_LINK([$1],[$2],[
2359         cf_cv_find_linkage_$3=yes
2360         cf_cv_header_path_$3=/usr/include
2361         cf_cv_library_path_$3=/usr/lib
2362         cf_cv_library_file_$3="-l$3"
2363 ],[
2364         cf_cv_find_linkage_$3=no
2365         LIBS="$cf_save_LIBS"
2366
2367         CF_VERBOSE(find linkage for $3 library)
2368         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
2369
2370         cf_save_CPPFLAGS="$CPPFLAGS"
2371         cf_test_CPPFLAGS="$CPPFLAGS"
2372
2373         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
2374         for cf_cv_header_path_$3 in $cf_search
2375         do
2376                 if test -d "$cf_cv_header_path_$3" ; then
2377                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
2378                         CPPFLAGS="$cf_save_CPPFLAGS"
2379                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
2380                         AC_TRY_COMPILE([$1],[$2],[
2381                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
2382                                 cf_cv_find_linkage_$3=maybe
2383                                 cf_test_CPPFLAGS="$CPPFLAGS"
2384                                 break],[
2385                                 CPPFLAGS="$cf_save_CPPFLAGS"
2386                                 ])
2387                 fi
2388         done
2389
2390         if test "$cf_cv_find_linkage_$3" = maybe ; then
2391
2392                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
2393
2394                 cf_save_LIBS="$LIBS"
2395                 cf_save_LDFLAGS="$LDFLAGS"
2396
2397                 ifelse([$6],,,[
2398                 CPPFLAGS="$cf_test_CPPFLAGS"
2399                 LIBS="-l$3 $7 $cf_save_LIBS"
2400                 AC_TRY_LINK([$1],[$2],[
2401                         CF_VERBOSE(... found $3 library in system)
2402                         cf_cv_find_linkage_$3=yes])
2403                         CPPFLAGS="$cf_save_CPPFLAGS"
2404                         LIBS="$cf_save_LIBS"
2405                         ])
2406
2407                 if test "$cf_cv_find_linkage_$3" != yes ; then
2408                         CF_LIBRARY_PATH(cf_search,$3)
2409                         for cf_cv_library_path_$3 in $cf_search
2410                         do
2411                                 if test -d "$cf_cv_library_path_$3" ; then
2412                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
2413                                         CPPFLAGS="$cf_test_CPPFLAGS"
2414                                         LIBS="-l$3 $7 $cf_save_LIBS"
2415                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
2416                                         AC_TRY_LINK([$1],[$2],[
2417                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
2418                                         cf_cv_find_linkage_$3=yes
2419                                         cf_cv_library_file_$3="-l$3"
2420                                         break],[
2421                                         CPPFLAGS="$cf_save_CPPFLAGS"
2422                                         LIBS="$cf_save_LIBS"
2423                                         LDFLAGS="$cf_save_LDFLAGS"
2424                                         ])
2425                                 fi
2426                         done
2427                         CPPFLAGS="$cf_save_CPPFLAGS"
2428                         LDFLAGS="$cf_save_LDFLAGS"
2429                 fi
2430
2431         else
2432                 cf_cv_find_linkage_$3=no
2433         fi
2434         ],$7)
2435 ])
2436
2437 LIBS="$cf_save_LIBS"
2438
2439 if test "$cf_cv_find_linkage_$3" = yes ; then
2440 ifelse([$4],,[
2441         CF_ADD_INCDIR($cf_cv_header_path_$3)
2442         CF_ADD_LIBDIR($cf_cv_library_path_$3)
2443         CF_ADD_LIB($3)
2444 ],[$4])
2445 else
2446 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
2447 fi
2448 ])dnl
2449 dnl ---------------------------------------------------------------------------
2450 dnl CF_FIND_SUB_INCDIR version: 3 updated: 2021/01/01 13:31:04
2451 dnl ------------------
2452 dnl Find an include-directory with the given leaf-name.  This is useful for
2453 dnl example with FreeBSD ports, which use this convention to distinguish
2454 dnl different versions of the same port.
2455 AC_DEFUN([CF_FIND_SUB_INCDIR],[
2456         CF_SUBDIR_PATH(cf_search,$1,include)
2457         for cf_item in $cf_search
2458         do
2459                 case "$cf_item" in
2460                 (*/$1)
2461                         CF_ADD_INCDIR($cf_item)
2462                         ;;
2463                 esac
2464         done
2465 ])dnl
2466 dnl ---------------------------------------------------------------------------
2467 dnl CF_FIND_SUB_LIBDIR version: 3 updated: 2021/01/01 13:31:04
2468 dnl ------------------
2469 dnl Find a library-directory with the given leaf-name.  This is useful for
2470 dnl example with FreeBSD ports, which use this convention to distinguish
2471 dnl different versions of the same port.
2472 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
2473         CF_SUBDIR_PATH(cf_search,$1,lib)
2474         for cf_item in $cf_search
2475         do
2476                 case "$cf_item" in
2477                 (*/$1)
2478                         CF_ADD_LIBDIR($cf_item)
2479                         ;;
2480                 esac
2481         done
2482 ])dnl
2483 dnl ---------------------------------------------------------------------------
2484 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
2485 dnl -----------------
2486 dnl make ADAFLAGS consistent with CFLAGS
2487 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
2488         AC_MSG_CHECKING(optimization options for ADAFLAGS)
2489         case "$CFLAGS" in
2490         (*-g*)
2491                 CF_ADD_ADAFLAGS(-g)
2492                 ;;
2493         esac
2494         case "$CFLAGS" in
2495         (*-O*)
2496                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
2497                 CF_ADD_ADAFLAGS($cf_O_flag)
2498                 ;;
2499         esac
2500         AC_MSG_RESULT($ADAFLAGS)
2501 ])dnl
2502 dnl ---------------------------------------------------------------------------
2503 dnl CF_FIX_WARNINGS version: 4 updated: 2021/12/16 18:22:31
2504 dnl ---------------
2505 dnl Warning flags do not belong in CFLAGS, CPPFLAGS, etc.  Any of gcc's
2506 dnl "-Werror" flags can interfere with configure-checks.  Those go into
2507 dnl EXTRA_CFLAGS.
2508 dnl
2509 dnl $1 = variable name to repair
2510 define([CF_FIX_WARNINGS],[
2511 if test "$GCC" = yes || test "$GXX" = yes
2512 then
2513         case [$]$1 in
2514         (*-Werror=*)
2515                 cf_temp_flags=
2516                 for cf_temp_scan in [$]$1
2517                 do
2518                         case "x$cf_temp_scan" in
2519                         (x-Werror=format*)
2520                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
2521                                 ;;
2522                         (x-Werror=*)
2523                                 CF_APPEND_TEXT(EXTRA_CFLAGS,$cf_temp_scan)
2524                                 ;;
2525                         (*)
2526                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
2527                                 ;;
2528                         esac
2529                 done
2530                 if test "x[$]$1" != "x$cf_temp_flags"
2531                 then
2532                         CF_VERBOSE(repairing $1: [$]$1)
2533                         $1="$cf_temp_flags"
2534                         CF_VERBOSE(... fixed [$]$1)
2535                         CF_VERBOSE(... extra $EXTRA_CFLAGS)
2536                 fi
2537                 ;;
2538         esac
2539 fi
2540 AC_SUBST(EXTRA_CFLAGS)
2541 ])dnl
2542 dnl ---------------------------------------------------------------------------
2543 dnl CF_FOPEN_BIN_R version: 3 updated: 2023/01/05 18:05:46
2544 dnl --------------
2545 dnl Check if fopen works when the "b" (binary) flag is added to the mode
2546 dnl parameter.  POSIX ignores the "b", which c89 specified.  Some very old
2547 dnl systems do not accept it.
2548 AC_DEFUN([CF_FOPEN_BIN_R],[
2549 AC_CACHE_CHECK(if fopen accepts explicit binary mode,cf_cv_fopen_bin_r,[
2550         AC_TRY_RUN([
2551 $ac_includes_default
2552
2553 int main(void)
2554 {
2555         FILE *fp = fopen("conftest.tmp", "wb");
2556         int rc = 0;
2557         if (fp != 0) {
2558                 int p, q;
2559                 for (p = 0; p < 256; ++p) {
2560                         fputc(p, fp);
2561                 }
2562                 fclose(fp);
2563                 fp = fopen("conftest.tmp", "rb");
2564                 if (fp != 0) {
2565                         for (p = 0; p < 256; ++p) {
2566                                 q = fgetc(fp);
2567                                 if (q != p) {
2568                                         rc = 1;
2569                                         break;
2570                                 }
2571                         }
2572                 } else {
2573                         rc = 1;
2574                 }
2575         } else {
2576                 rc = 1;
2577         }
2578         ${cf_cv_main_return:-return} (rc);
2579 }
2580 ],
2581                 [cf_cv_fopen_bin_r=yes],
2582                 [cf_cv_fopen_bin_r=no],
2583                 [cf_cv_fopen_bin_r=unknown])
2584 ])
2585 test "x$cf_cv_fopen_bin_r" != xno && AC_DEFINE(USE_FOPEN_BIN_R,1,[Define to 1 if fopen accepts explicit binary mode])
2586 ])dnl
2587 dnl ---------------------------------------------------------------------------
2588 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
2589 dnl --------------
2590 dnl Forget that we saw the given tool.
2591 AC_DEFUN([CF_FORGET_TOOL],[
2592 unset ac_cv_prog_ac_ct_$1
2593 unset ac_ct_$1
2594 unset $1
2595 ])dnl
2596 dnl ---------------------------------------------------------------------------
2597 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
2598 dnl -------------
2599 dnl Test for dlsym() and related functions, as well as libdl.
2600 dnl
2601 dnl Sets
2602 dnl     $cf_have_dlsym
2603 dnl     $cf_have_libdl
2604 AC_DEFUN([CF_FUNC_DLSYM],[
2605 cf_have_dlsym=no
2606 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
2607
2608 cf_have_libdl=no
2609 AC_CHECK_LIB(dl,dlsym,[
2610         cf_have_dlsym=yes
2611         cf_have_libdl=yes])])
2612
2613 if test "$cf_have_dlsym" = yes ; then
2614         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
2615
2616         AC_MSG_CHECKING(whether able to link to dl*() functions)
2617         AC_TRY_LINK([#include <dlfcn.h>],[
2618                 void *obj;
2619                 if ((obj = dlopen("filename", 0)) != 0) {
2620                         if (dlsym(obj, "symbolname") == 0) {
2621                         dlclose(obj);
2622                         }
2623                 }],[
2624                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
2625                 AC_MSG_ERROR(Cannot link test program for libdl)])
2626         AC_MSG_RESULT(ok)
2627 else
2628         AC_MSG_ERROR(Cannot find dlsym function)
2629 fi
2630 ])
2631 dnl ---------------------------------------------------------------------------
2632 dnl CF_FUNC_GETTTYNAM version: 2 updated: 2023/01/05 18:06:28
2633 dnl -----------------
2634 dnl Check if the 4.3BSD function getttyname exists, as well as if <ttyent.h>
2635 dnl defines the _PATH_TTYS symbol.  If the corresponding file exists, but the
2636 dnl other checks fail, just define HAVE_PATH_TTYS.
2637 AC_DEFUN([CF_FUNC_GETTTYNAM],[
2638 AC_CACHE_CHECK(if _PATH_TTYS is defined in ttyent.h,cf_cv_PATH_TTYS,[
2639 AC_TRY_COMPILE([
2640 #include <stdio.h>
2641 #include <ttyent.h>],[
2642 FILE *fp = fopen(_PATH_TTYS, "r"); (void)fp],
2643         [cf_cv_PATH_TTYS=yes],
2644         [cf_cv_PATH_TTYS=no])])
2645
2646 if test $cf_cv_PATH_TTYS = no
2647 then
2648         for cf_ttys in /etc/ttytype /etc/ttys
2649         do
2650                 if test -f $cf_ttys
2651                 then
2652                         cf_cv_PATH_TTYS=maybe
2653                         AC_DEFINE(_PATH_TTYS,$cf_ttys,[define to pathname of file containing mapping from tty name to terminal type])
2654                         break
2655                 fi
2656         done
2657 fi
2658
2659 if test $cf_cv_PATH_TTYS != no
2660 then
2661         AC_CACHE_CHECK(if _PATH_TTYS file exists,cf_cv_have_PATH_TTYS,[
2662                 AC_TRY_RUN([
2663 $ac_includes_default
2664
2665 #include <ttyent.h>
2666
2667 int main(void) {
2668         FILE *fp = fopen(_PATH_TTYS, "r");
2669         ${cf_cv_main_return:-return} (fp == 0);
2670 }],
2671                         [cf_cv_have_PATH_TTYS=yes],
2672                         [cf_cv_have_PATH_TTYS=no],
2673                         [cf_cv_have_PATH_TTYS=unknown])])
2674         test "$cf_cv_have_PATH_TTYS" = no && cf_cv_PATH_TTYS=no
2675 fi
2676
2677 if test $cf_cv_PATH_TTYS != no
2678 then
2679         AC_DEFINE(HAVE_PATH_TTYS,1,[define to 1 if system can map tty name to terminal type])
2680         AC_CACHE_CHECK(for getttynam,cf_cv_func_getttynam,[
2681                 AC_TRY_LINK([#include <ttyent.h>],
2682                 [struct ttyent *fp = getttynam("/dev/tty"); (void)fp],
2683                 [cf_cv_func_getttynam=yes],
2684                 [cf_cv_func_getttynam=no])])
2685         test "$cf_cv_func_getttynam" = yes && AC_DEFINE(HAVE_GETTTYNAM)
2686 fi
2687 ])dnl
2688 dnl ---------------------------------------------------------------------------
2689 dnl CF_FUNC_MEMMOVE version: 10 updated: 2023/01/05 18:51:28
2690 dnl ---------------
2691 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
2692 dnl is found, add our own version of memmove to the list of objects.
2693 AC_DEFUN([CF_FUNC_MEMMOVE],
2694 [
2695 AC_CHECK_FUNC(memmove,,[
2696 AC_CHECK_FUNC(bcopy,[
2697         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
2698                 AC_TRY_RUN([
2699 $ac_includes_default
2700
2701 int main(void) {
2702         static char data[] = "abcdefghijklmnopqrstuwwxyz";
2703         char temp[40];
2704         bcopy(data, temp, sizeof(data));
2705         bcopy(temp+10, temp, 15);
2706         bcopy(temp+5, temp+15, 10);
2707         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
2708 }
2709                 ],
2710                 [cf_cv_good_bcopy=yes],
2711                 [cf_cv_good_bcopy=no],
2712                 [cf_cv_good_bcopy=unknown])
2713                 ])
2714         ],[cf_cv_good_bcopy=no])
2715         if test "$cf_cv_good_bcopy" = yes ; then
2716                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
2717         else
2718                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
2719         fi
2720 ])])dnl
2721 dnl ---------------------------------------------------------------------------
2722 dnl CF_FUNC_NANOSLEEP version: 6 updated: 2023/01/05 18:51:33
2723 dnl -----------------
2724 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
2725 dnl AIX 4.x, provide a non-working version.
2726 AC_DEFUN([CF_FUNC_NANOSLEEP],[
2727 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
2728 AC_TRY_RUN([
2729 $ac_includes_default
2730
2731 #include <errno.h>
2732 #include <time.h>
2733
2734 #ifdef HAVE_SYS_TIME_H
2735 #include <sys/time.h>
2736 #endif
2737
2738 int main(void) {
2739         struct timespec ts1, ts2;
2740         int code;
2741         ts1.tv_sec  = 0;
2742         ts1.tv_nsec = 750000000;
2743         ts2.tv_sec  = 0;
2744         ts2.tv_nsec = 0;
2745         errno = 0;
2746         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
2747         ${cf_cv_main_return:-return}(code != 0);
2748 }
2749 ],
2750         [cf_cv_func_nanosleep=yes],
2751         [cf_cv_func_nanosleep=no],
2752         [cf_cv_func_nanosleep=unknown])])
2753
2754 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
2755 ])
2756 dnl ---------------------------------------------------------------------------
2757 dnl CF_FUNC_OPENPTY version: 6 updated: 2021/01/01 13:31:04
2758 dnl ---------------
2759 dnl Check for openpty() function, along with <pty.h> header.  It may need the
2760 dnl "util" library as well.
2761 AC_DEFUN([CF_FUNC_OPENPTY],
2762 [
2763 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
2764 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
2765         cf_save_LIBS="$LIBS"
2766         test "$cf_cv_lib_util" = yes && { CF_ADD_LIB(util) }
2767         for cf_header in pty.h libutil.h util.h
2768         do
2769         AC_TRY_LINK([
2770 #include <$cf_header>
2771 ],[
2772         int x = openpty((int *)0, (int *)0, (char *)0,
2773                                    (struct termios *)0, (struct winsize *)0);
2774 ],[
2775                 cf_cv_func_openpty=$cf_header
2776                 break
2777 ],[
2778                 cf_cv_func_openpty=no
2779 ])
2780         done
2781         LIBS="$cf_save_LIBS"
2782 ])
2783 ])dnl
2784 dnl ---------------------------------------------------------------------------
2785 dnl CF_FUNC_POLL version: 11 updated: 2023/01/05 18:51:40
2786 dnl ------------
2787 dnl See if the poll function really works.  Some platforms have poll(), but
2788 dnl it does not work for terminals or files.
2789 AC_DEFUN([CF_FUNC_POLL],[
2790 tty >/dev/null 2>&1 || { AC_CHECK_FUNCS(posix_openpt) }
2791 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2792 AC_TRY_RUN([
2793 $ac_includes_default
2794
2795 #include <fcntl.h>
2796
2797 #ifdef HAVE_POLL_H
2798 #include <poll.h>
2799 #else
2800 #include <sys/poll.h>
2801 #endif
2802
2803 int main(void) {
2804         struct pollfd myfds;
2805         int ret;
2806
2807         /* check for Darwin bug with respect to "devices" */
2808         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2809         if (myfds.fd < 0)
2810                 myfds.fd = 0;
2811         myfds.events = POLLIN;
2812         myfds.revents = 0;
2813
2814         ret = poll(&myfds, 1, 100);
2815
2816         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2817                 ret = -1;
2818         } else {
2819                 int fd = 0;
2820                 if (!isatty(fd)) {
2821                         fd = open("/dev/tty", 2);       /* O_RDWR */
2822                 }
2823 #ifdef HAVE_POSIX_OPENPT
2824                 if (fd < 0) {
2825                         fd = posix_openpt(O_RDWR);
2826                 }
2827 #endif
2828
2829                 if (fd >= 0) {
2830                         /* also check with standard input */
2831                         myfds.fd = fd;
2832                         myfds.events = POLLIN;
2833                         myfds.revents = 0;
2834                         ret = poll(&myfds, 1, 100);
2835                 } else {
2836                         ret = -1;
2837                 }
2838         }
2839         ${cf_cv_main_return:-return}(ret < 0);
2840 }],
2841         [cf_cv_working_poll=yes],
2842         [cf_cv_working_poll=no],
2843         [cf_cv_working_poll=unknown])])
2844 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2845 ])dnl
2846 dnl ---------------------------------------------------------------------------
2847 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2848 dnl ---------------
2849 dnl Some old/broken variations define tcgetattr() only as a macro in
2850 dnl termio(s).h
2851 AC_DEFUN([CF_FUNC_TERMIOS],[
2852 AC_REQUIRE([CF_STRUCT_TERMIOS])
2853 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2854 AC_TRY_LINK([
2855 #include <sys/types.h>
2856 #ifdef HAVE_UNISTD_H
2857 #include <unistd.h>
2858 #endif
2859 #ifdef HAVE_TERMIOS_H
2860 #include <termios.h>
2861 #define TTY struct termios
2862 #else
2863 #ifdef HAVE_TERMIO_H
2864 #include <termio.h>
2865 #define TTY struct termio
2866 #endif
2867 #endif
2868 ],[
2869 TTY foo;
2870 tcgetattr(1, &foo);],
2871 [cf_cv_have_tcgetattr=yes],
2872 [cf_cv_have_tcgetattr=no])])
2873 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2874 ])dnl
2875 dnl ---------------------------------------------------------------------------
2876 dnl CF_FUNC_VSSCANF version: 7 updated: 2021/01/01 13:31:04
2877 dnl ---------------
2878 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2879 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2880 dnl other functions.
2881 AC_DEFUN([CF_FUNC_VSSCANF],
2882 [
2883 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2884 AC_TRY_LINK([
2885 #include <stdarg.h>
2886 #include <stdio.h>],[
2887         va_list ap;
2888         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2889 AC_TRY_LINK([
2890 #include <stdarg.h>
2891 #include <stdio.h>],[
2892         FILE strbuf;
2893         char *str = "from";
2894
2895         strbuf._flag = _IOREAD;
2896         strbuf._ptr = strbuf._base = (unsigned char *) str;
2897         strbuf._cnt = strlen(str);
2898         strbuf._file = _NFILE;
2899         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2900 AC_TRY_LINK([
2901 #include <stdarg.h>
2902 #include <stdio.h>],[
2903         FILE strbuf;
2904         char *str = "from";
2905
2906         strbuf._flag = _IOREAD;
2907         strbuf._ptr = strbuf._base = (unsigned char *) str;
2908         strbuf._cnt = strlen(str);
2909         strbuf._file = _NFILE;
2910         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2911 cf_cv_func_vsscanf=no])])])])
2912
2913 case "$cf_cv_func_vsscanf" in
2914 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2915 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2916 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2917 esac
2918
2919 ])dnl
2920 dnl ---------------------------------------------------------------------------
2921 dnl CF_GCC_ATTRIBUTES version: 24 updated: 2021/03/20 12:00:25
2922 dnl -----------------
2923 dnl Test for availability of useful gcc __attribute__ directives to quiet
2924 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2925 dnl to documentation, unrecognized directives cause older compilers to barf.
2926 AC_DEFUN([CF_GCC_ATTRIBUTES],
2927 [AC_REQUIRE([AC_PROG_FGREP])dnl
2928 AC_REQUIRE([CF_C11_NORETURN])dnl
2929
2930 if test "$GCC" = yes || test "$GXX" = yes
2931 then
2932 cat > conftest.i <<EOF
2933 #ifndef GCC_PRINTF
2934 #define GCC_PRINTF 0
2935 #endif
2936 #ifndef GCC_SCANF
2937 #define GCC_SCANF 0
2938 #endif
2939 #ifndef GCC_NORETURN
2940 #define GCC_NORETURN /* nothing */
2941 #endif
2942 #ifndef GCC_UNUSED
2943 #define GCC_UNUSED /* nothing */
2944 #endif
2945 EOF
2946 if test "$GCC" = yes
2947 then
2948         AC_CHECKING([for $CC __attribute__ directives])
2949 cat > "conftest.$ac_ext" <<EOF
2950 #line __oline__ "${as_me:-configure}"
2951 #include <stdio.h>
2952 #include "confdefs.h"
2953 #include "conftest.h"
2954 #include "conftest.i"
2955 #if     GCC_PRINTF
2956 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2957 #else
2958 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2959 #endif
2960 #if     GCC_SCANF
2961 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2962 #else
2963 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2964 #endif
2965 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2966 extern GCC_NORETURN void oops(char *,...) GCC_PRINTFLIKE(1,2);
2967 extern GCC_NORETURN void foo(void);
2968 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
2969 EOF
2970         cf_printf_attribute=no
2971         cf_scanf_attribute=no
2972         for cf_attribute in scanf printf unused noreturn
2973         do
2974                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2975                 cf_directive="__attribute__(($cf_attribute))"
2976                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2977
2978                 case "$cf_attribute" in
2979                 (printf)
2980                         cf_printf_attribute=yes
2981                         cat >conftest.h <<EOF
2982 #define GCC_$cf_ATTRIBUTE 1
2983 EOF
2984                         ;;
2985                 (scanf)
2986                         cf_scanf_attribute=yes
2987                         cat >conftest.h <<EOF
2988 #define GCC_$cf_ATTRIBUTE 1
2989 EOF
2990                         ;;
2991                 (*)
2992                         cat >conftest.h <<EOF
2993 #define GCC_$cf_ATTRIBUTE $cf_directive
2994 EOF
2995                         ;;
2996                 esac
2997
2998                 if AC_TRY_EVAL(ac_compile); then
2999                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
3000                         cat conftest.h >>confdefs.h
3001                         case "$cf_attribute" in
3002                         (noreturn)
3003                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
3004                                 ;;
3005                         (printf)
3006                                 cf_value='/* nothing */'
3007                                 if test "$cf_printf_attribute" != no ; then
3008                                         cf_value='__attribute__((format(printf,fmt,var)))'
3009                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
3010                                 fi
3011                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
3012                                 ;;
3013                         (scanf)
3014                                 cf_value='/* nothing */'
3015                                 if test "$cf_scanf_attribute" != no ; then
3016                                         cf_value='__attribute__((format(scanf,fmt,var)))'
3017                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
3018                                 fi
3019                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
3020                                 ;;
3021                         (unused)
3022                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
3023                                 ;;
3024                         esac
3025                 fi
3026         done
3027 else
3028         ${FGREP-fgrep} define conftest.i >>confdefs.h
3029 fi
3030 rm -rf ./conftest*
3031 fi
3032 ])dnl
3033 dnl ---------------------------------------------------------------------------
3034 dnl CF_GCC_VERSION version: 8 updated: 2019/09/07 13:38:36
3035 dnl --------------
3036 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
3037 dnl compatible), attempt to determine if icc/clang is actually used.
3038 AC_DEFUN([CF_GCC_VERSION],[
3039 AC_REQUIRE([AC_PROG_CC])
3040 GCC_VERSION=none
3041 if test "$GCC" = yes ; then
3042         AC_MSG_CHECKING(version of $CC)
3043         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
3044         test -z "$GCC_VERSION" && GCC_VERSION=unknown
3045         AC_MSG_RESULT($GCC_VERSION)
3046 fi
3047 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
3048 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
3049 ])dnl
3050 dnl ---------------------------------------------------------------------------
3051 dnl CF_GCC_WARNINGS version: 41 updated: 2021/01/01 16:53:59
3052 dnl ---------------
3053 dnl Check if the compiler supports useful warning options.  There's a few that
3054 dnl we don't use, simply because they're too noisy:
3055 dnl
3056 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
3057 dnl     -Winline (usually not worthwhile)
3058 dnl     -Wredundant-decls (system headers make this too noisy)
3059 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
3060 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
3061 dnl             is enabled for ncurses using "--enable-const".
3062 dnl     -pedantic
3063 dnl
3064 dnl Parameter:
3065 dnl     $1 is an optional list of gcc warning flags that a particular
3066 dnl             application might want to use, e.g., "no-unused" for
3067 dnl             -Wno-unused
3068 dnl Special:
3069 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
3070 dnl
3071 AC_DEFUN([CF_GCC_WARNINGS],
3072 [
3073 AC_REQUIRE([CF_GCC_VERSION])
3074 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
3075 cat > "conftest.$ac_ext" <<EOF
3076 #line __oline__ "${as_me:-configure}"
3077 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
3078 EOF
3079 if test "$INTEL_COMPILER" = yes
3080 then
3081 # The "-wdXXX" options suppress warnings:
3082 # remark #1419: external declaration in primary source file
3083 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3084 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
3085 # remark #193: zero used for undefined preprocessing identifier
3086 # remark #593: variable "curs_sb_left_arrow" was set but never used
3087 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
3088 # remark #869: parameter "tw" was never referenced
3089 # remark #981: operands are evaluated in unspecified order
3090 # warning #279: controlling expression is constant
3091
3092         AC_CHECKING([for $CC warning options])
3093         cf_save_CFLAGS="$CFLAGS"
3094         EXTRA_CFLAGS="$EXTRA_CFLAGS -Wall"
3095         for cf_opt in \
3096                 wd1419 \
3097                 wd1683 \
3098                 wd1684 \
3099                 wd193 \
3100                 wd593 \
3101                 wd279 \
3102                 wd810 \
3103                 wd869 \
3104                 wd981
3105         do
3106                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
3107                 if AC_TRY_EVAL(ac_compile); then
3108                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3109                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
3110                 fi
3111         done
3112         CFLAGS="$cf_save_CFLAGS"
3113 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
3114 then
3115         AC_CHECKING([for $CC warning options])
3116         cf_save_CFLAGS="$CFLAGS"
3117         cf_warn_CONST=""
3118         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
3119         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
3120         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
3121         for cf_opt in W Wall \
3122                 Wbad-function-cast \
3123                 Wcast-align \
3124                 Wcast-qual \
3125                 Wdeclaration-after-statement \
3126                 Wextra \
3127                 Winline \
3128                 Wmissing-declarations \
3129                 Wmissing-prototypes \
3130                 Wnested-externs \
3131                 Wpointer-arith \
3132                 Wshadow \
3133                 Wstrict-prototypes \
3134                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
3135         do
3136                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
3137                 if AC_TRY_EVAL(ac_compile); then
3138                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3139                         case "$cf_opt" in
3140                         (Winline)
3141                                 case "$GCC_VERSION" in
3142                                 ([[34]].*)
3143                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
3144                                         continue;;
3145                                 esac
3146                                 ;;
3147                         (Wpointer-arith)
3148                                 case "$GCC_VERSION" in
3149                                 ([[12]].*)
3150                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
3151                                         continue;;
3152                                 esac
3153                                 ;;
3154                         esac
3155                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
3156                 fi
3157         done
3158         CFLAGS="$cf_save_CFLAGS"
3159 fi
3160 rm -rf ./conftest*
3161
3162 AC_SUBST(EXTRA_CFLAGS)
3163 ])dnl
3164 dnl ---------------------------------------------------------------------------
3165 dnl CF_GETOPT_HEADER version: 8 updated: 2021/06/19 19:16:16
3166 dnl ----------------
3167 dnl Check for getopt's variables which are commonly defined in stdlib.h,
3168 dnl unistd.h or (nonstandard) in getopt.h
3169 AC_DEFUN([CF_GETOPT_HEADER],
3170 [
3171 AC_HAVE_HEADERS(unistd.h getopt.h)
3172 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
3173 cf_cv_getopt_header=none
3174 for cf_header in stdio.h stdlib.h unistd.h getopt.h
3175 do
3176 AC_TRY_COMPILE([
3177 #include <$cf_header>],
3178 [int x = optind; char *y = optarg; (void)x; (void)y],
3179 [cf_cv_getopt_header=$cf_header
3180  break])
3181 done
3182 ])
3183 if test "$cf_cv_getopt_header" != none ; then
3184         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
3185 fi
3186 if test "$cf_cv_getopt_header" = getopt.h ; then
3187         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
3188 fi
3189 ])dnl
3190 dnl ---------------------------------------------------------------------------
3191 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
3192 dnl -----------------
3193 AC_DEFUN([CF_GNATPREP_OPT_T],[
3194 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
3195 cf_cv_gnatprep_opt_t=no
3196 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
3197 ])
3198 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
3199 AC_SUBST(GNATPREP_OPTS)
3200 ])dnl
3201 dnl ---------------------------------------------------------------------------
3202 dnl CF_GNAT_GENERICS version: 7 updated: 2021/01/01 13:31:04
3203 dnl ----------------
3204 AC_DEFUN([CF_GNAT_GENERICS],
3205 [
3206 AC_REQUIRE([CF_GNAT_VERSION])
3207
3208 AC_MSG_CHECKING(if GNAT supports generics)
3209 case "$cf_cv_gnat_version" in
3210 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
3211         cf_gnat_generics=yes
3212         ;;
3213 (*)
3214         cf_gnat_generics=no
3215         ;;
3216 esac
3217 AC_MSG_RESULT($cf_gnat_generics)
3218
3219 if test "$cf_gnat_generics" = yes
3220 then
3221         cf_compile_generics=generics
3222         cf_generic_objects="\${GENOBJS}"
3223 else
3224         cf_compile_generics=
3225         cf_generic_objects=
3226 fi
3227
3228 AC_SUBST(cf_compile_generics)
3229 AC_SUBST(cf_generic_objects)
3230 ])dnl
3231 dnl ---------------------------------------------------------------------------
3232 dnl CF_GNAT_PROJECTS version: 13 updated: 2021/01/02 17:09:14
3233 dnl ----------------
3234 dnl GNAT projects are configured with ".gpr" project files.
3235 dnl GNAT libraries are a further development, using the project feature.
3236 AC_DEFUN([CF_GNAT_PROJECTS],
3237 [
3238 AC_REQUIRE([CF_GNAT_VERSION])
3239 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
3240
3241 cf_gnat_libraries=no
3242 cf_gnat_projects=no
3243
3244 if test "$enable_gnat_projects" != no ; then
3245 AC_MSG_CHECKING(if GNAT supports project files)
3246 case "$cf_cv_gnat_version" in
3247 (3.[[0-9]]*)
3248         ;;
3249 (*)
3250         case "$cf_cv_system_name" in
3251         (cygwin*|msys*)
3252                 ;;
3253         (*)
3254                 rm -rf ./conftest* ./*~conftest*
3255                 if mkdir conftest.src conftest.bin conftest.lib
3256                 then
3257                         cd conftest.src
3258                         rm -rf ./conftest* ./*~conftest*
3259                         cat >>library.gpr <<CF_EOF
3260 project Library is
3261   Kind := External ("LIB_KIND");
3262   for Library_Name use "ConfTest";
3263   for Object_Dir use ".";
3264   for Library_ALI_Dir use External("LIBRARY_DIR");
3265   for Library_Version use External ("SONAME");
3266   for Library_Kind use Kind;
3267   for Library_Dir use External("BUILD_DIR");
3268   Source_Dir := External ("SOURCE_DIR");
3269   for Source_Dirs use (Source_Dir);
3270 end Library;
3271 CF_EOF
3272                         cat >>confpackage.ads <<CF_EOF
3273 package ConfPackage is
3274    procedure conftest;
3275 end ConfPackage;
3276 CF_EOF
3277                         cat >>confpackage.adb <<CF_EOF
3278 with Text_IO;
3279 package body ConfPackage is
3280    procedure conftest is
3281    begin
3282       Text_IO.Put ("Hello World");
3283       Text_IO.New_Line;
3284    end conftest;
3285 end ConfPackage;
3286 CF_EOF
3287                         if ( "$cf_ada_make" $ADAFLAGS \
3288                                         -Plibrary.gpr \
3289                                         -XBUILD_DIR="`cd ../conftest.bin;pwd`" \
3290                                         -XLIBRARY_DIR="`cd ../conftest.lib;pwd`" \
3291                                         -XSOURCE_DIR="`pwd`" \
3292                                         -XSONAME=libConfTest.so.1 \
3293                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
3294                                 cf_gnat_projects=yes
3295                         fi
3296                         cd ..
3297                 fi
3298                 if test -f conftest.lib/confpackage.ali
3299                 then
3300                         cf_gnat_libraries=yes
3301                 fi
3302                 rm -rf ./conftest* ./*~conftest*
3303                 ;;
3304         esac
3305         ;;
3306 esac
3307 AC_MSG_RESULT($cf_gnat_projects)
3308 fi # enable_gnat_projects
3309
3310 if test "$cf_gnat_projects" = yes
3311 then
3312         AC_MSG_CHECKING(if GNAT supports libraries)
3313         AC_MSG_RESULT($cf_gnat_libraries)
3314 fi
3315
3316 USE_OLD_MAKERULES=""
3317 USE_GNAT_PROJECTS="#"
3318 USE_GNAT_MAKE_GPR="#"
3319 USE_GNAT_GPRBUILD="#"
3320
3321 if test "$cf_gnat_projects" = yes
3322 then
3323         USE_OLD_MAKERULES="#"
3324         USE_GNAT_PROJECTS=""
3325         if test "$cf_cv_VERSION_GPRBUILD" != no
3326         then
3327                 USE_GNAT_GPRBUILD=""
3328         elif test "$cf_cv_VERSION_GNATMAKE" != no
3329         then
3330                 USE_GNAT_MAKE_GPR=""
3331         else
3332                 AC_MSG_WARN(use old makefile rules since tools are missing)
3333         fi
3334 fi
3335
3336 if test "$cf_gnat_libraries" = yes
3337 then
3338         USE_GNAT_LIBRARIES=""
3339 else
3340         USE_GNAT_LIBRARIES="#"
3341 fi
3342
3343 AC_SUBST(USE_OLD_MAKERULES)
3344 AC_SUBST(USE_GNAT_PROJECTS)
3345 AC_SUBST(USE_GNAT_LIBRARIES)
3346 AC_SUBST(USE_GNAT_MAKE_GPR)
3347 AC_SUBST(USE_GNAT_GPRBUILD)
3348 ])dnl
3349 dnl ---------------------------------------------------------------------------
3350 dnl CF_GNAT_SIGINT version: 2 updated: 2021/01/01 13:31:04
3351 dnl --------------
3352 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
3353 dnl is noted that gnat may compile a tasking unit even for configurations which
3354 dnl fail at runtime.
3355 AC_DEFUN([CF_GNAT_SIGINT],[
3356 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
3357 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
3358
3359 package ConfTest is
3360
3361    pragma Warnings (Off);  --  the next pragma exists since 3.11p
3362    pragma Unreserve_All_Interrupts;
3363    pragma Warnings (On);
3364
3365    protected Process is
3366       procedure Stop;
3367       function Continue return Boolean;
3368       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
3369    private
3370       Done : Boolean := False;
3371    end Process;
3372
3373 end ConfTest;],
3374 [package body ConfTest is
3375    protected body Process is
3376       procedure Stop is
3377       begin
3378          Done := True;
3379       end Stop;
3380       function Continue return Boolean is
3381       begin
3382          return not Done;
3383       end Continue;
3384    end Process;
3385 end ConfTest;],
3386         [cf_cv_gnat_sigint=yes],
3387         [cf_cv_gnat_sigint=no])])
3388
3389 if test "$cf_cv_gnat_sigint" = yes ; then
3390         USE_GNAT_SIGINT=""
3391 else
3392         USE_GNAT_SIGINT="#"
3393 fi
3394 AC_SUBST(USE_GNAT_SIGINT)
3395 ])dnl
3396 dnl ---------------------------------------------------------------------------
3397 dnl CF_GNAT_TRY_LINK version: 4 updated: 2021/01/01 13:31:04
3398 dnl ----------------
3399 dnl Verify that a test program compiles/links with GNAT.
3400 dnl $cf_ada_make is set to the program that compiles/links
3401 dnl $ADAFLAGS may be set to the GNAT flags.
3402 dnl
3403 dnl $1 is the text of the spec
3404 dnl $2 is the text of the body
3405 dnl $3 is the shell command to execute if successful
3406 dnl $4 is the shell command to execute if not successful
3407 AC_DEFUN([CF_GNAT_TRY_LINK],
3408 [
3409 rm -rf ./conftest* ./*~conftest*
3410 cat >>conftest.ads <<CF_EOF
3411 $1
3412 CF_EOF
3413 cat >>conftest.adb <<CF_EOF
3414 $2
3415 CF_EOF
3416 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3417 ifelse($3,,      :,[      $3])
3418 ifelse($4,,,[else
3419    $4])
3420 fi
3421 rm -rf ./conftest* ./*~conftest*
3422 ])dnl
3423 dnl ---------------------------------------------------------------------------
3424 dnl CF_GNAT_TRY_RUN version: 6 updated: 2021/01/01 13:31:04
3425 dnl ---------------
3426 dnl Verify that a test program compiles and runs with GNAT
3427 dnl $cf_ada_make is set to the program that compiles/links
3428 dnl $ADAFLAGS may be set to the GNAT flags.
3429 dnl
3430 dnl $1 is the text of the spec
3431 dnl $2 is the text of the body
3432 dnl $3 is the shell command to execute if successful
3433 dnl $4 is the shell command to execute if not successful
3434 AC_DEFUN([CF_GNAT_TRY_RUN],
3435 [
3436 rm -rf ./conftest* ./*~conftest*
3437 cat >>conftest.ads <<CF_EOF
3438 $1
3439 CF_EOF
3440 cat >>conftest.adb <<CF_EOF
3441 $2
3442 CF_EOF
3443 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3444    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
3445 ifelse($3,,      :,[      $3])
3446 ifelse($4,,,[   else
3447       $4])
3448    fi
3449 ifelse($4,,,[else
3450    $4])
3451 fi
3452 rm -rf ./conftest* ./*~conftest*
3453 ])dnl
3454 dnl ---------------------------------------------------------------------------
3455 dnl CF_GNAT_VERSION version: 22 updated: 2019/12/31 08:53:54
3456 dnl ---------------
3457 dnl $1 = cache variable to update
3458 dnl $2 = program name
3459 dnl Verify version of GNAT or related tool
3460 AC_DEFUN([CF_GNAT_VERSION],
3461 [
3462 AC_CACHE_CHECK(for ifelse($2,,gnat,$2) version, cf_cv_gnat_version,[
3463 cf_cv_gnat_version=`ifelse($2,,${cf_ada_make:-gnatmake},$2) --version 2>&1 | \
3464         grep '[[0-9]].[[0-9]][[0-9]]*' |\
3465         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
3466 ])
3467 test -z "$cf_cv_gnat_version" && cf_cv_gnat_version=no
3468 ifelse($1,,,[eval $1=$cf_cv_gnat_version; unset cf_cv_gnat_version])
3469 ])dnl
3470 dnl ---------------------------------------------------------------------------
3471 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
3472 dnl -------------
3473 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
3474 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
3475 dnl (or misfeature) of glibc2, which breaks portability of many applications,
3476 dnl since it is interwoven with GNU extensions.
3477 dnl
3478 dnl Well, yes we could work around it...
3479 dnl
3480 dnl Parameters:
3481 dnl     $1 is the nominal value for _XOPEN_SOURCE
3482 AC_DEFUN([CF_GNU_SOURCE],
3483 [
3484 cf_gnu_xopen_source=ifelse($1,,500,$1)
3485
3486 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
3487 AC_TRY_COMPILE([#include <sys/types.h>],[
3488         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
3489                 return 0;
3490         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
3491                 return 0;
3492         #else
3493         #       error not GNU C library
3494         #endif],
3495         [cf_cv_gnu_library=yes],
3496         [cf_cv_gnu_library=no])
3497 ])
3498
3499 if test x$cf_cv_gnu_library = xyes; then
3500
3501         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
3502         # was changed to help a little.  newlib incorporated the change about 4
3503         # years later.
3504         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
3505                 cf_save="$CPPFLAGS"
3506                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3507                 AC_TRY_COMPILE([#include <sys/types.h>],[
3508                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
3509                                 return 0;
3510                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
3511                                 return 0;
3512                         #else
3513                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
3514                         #endif],
3515                         [cf_cv_gnu_library_219=yes],
3516                         [cf_cv_gnu_library_219=no])
3517                 CPPFLAGS="$cf_save"
3518         ])
3519
3520         if test "x$cf_cv_gnu_library_219" = xyes; then
3521                 cf_save="$CPPFLAGS"
3522                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
3523                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
3524                         AC_TRY_COMPILE([
3525                                 #include <limits.h>
3526                                 #include <sys/types.h>
3527                                 ],[
3528                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
3529                                         return 0;
3530                                 #else
3531                                 #       error GNU C library is too old
3532                                 #endif],
3533                                 [cf_cv_gnu_dftsrc_219=yes],
3534                                 [cf_cv_gnu_dftsrc_219=no])
3535                         ])
3536                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
3537         else
3538                 cf_cv_gnu_dftsrc_219=maybe
3539         fi
3540
3541         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
3542
3543                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
3544                 AC_TRY_COMPILE([#include <sys/types.h>],[
3545                         #ifndef _XOPEN_SOURCE
3546                         #error  expected _XOPEN_SOURCE to be defined
3547                         #endif],
3548                         [cf_cv_gnu_source=no],
3549                         [cf_save="$CPPFLAGS"
3550                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
3551                          AC_TRY_COMPILE([#include <sys/types.h>],[
3552                                 #ifdef _XOPEN_SOURCE
3553                                 #error  expected _XOPEN_SOURCE to be undefined
3554                                 #endif],
3555                                 [cf_cv_gnu_source=no],
3556                                 [cf_cv_gnu_source=yes])
3557                         CPPFLAGS="$cf_save"
3558                         ])
3559                 ])
3560
3561                 if test "$cf_cv_gnu_source" = yes
3562                 then
3563                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
3564                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
3565                         AC_TRY_COMPILE([#include <sys/types.h>],[
3566                                 #ifdef _DEFAULT_SOURCE
3567                                 #error  expected _DEFAULT_SOURCE to be undefined
3568                                 #endif],
3569                                 [cf_cv_default_source=no],
3570                                 [cf_cv_default_source=yes])
3571                         ])
3572                         if test "$cf_cv_default_source" = yes
3573                         then
3574                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3575                         fi
3576                 fi
3577         fi
3578
3579 fi
3580 ])dnl
3581 dnl ---------------------------------------------------------------------------
3582 dnl CF_GPP_LIBRARY version: 13 updated: 2021/01/01 13:31:04
3583 dnl --------------
3584 dnl If we're trying to use g++, test if libg++ is installed (a rather common
3585 dnl problem :-).  If we have the compiler but no library, we'll be able to
3586 dnl configure, but won't be able to build the c++ demo program.
3587 AC_DEFUN([CF_GPP_LIBRARY],
3588 [
3589 cf_cxx_library=unknown
3590 case "$cf_cv_system_name" in
3591 (os2*)
3592         cf_gpp_libname=gpp
3593         ;;
3594 (*)
3595         cf_gpp_libname=g++
3596         ;;
3597 esac
3598 if test "$GXX" = yes; then
3599         AC_MSG_CHECKING([for lib$cf_gpp_libname])
3600         cf_save="$LIBS"
3601         CF_ADD_LIB($cf_gpp_libname)
3602         AC_TRY_LINK([
3603 #include <$cf_gpp_libname/builtin.h>
3604         ],
3605         [two_arg_error_handler_t foo2 = lib_error_handler],
3606         [cf_cxx_library=yes
3607          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3608          if test "$cf_gpp_libname" = cpp ; then
3609             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
3610          else
3611             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
3612          fi],
3613         [AC_TRY_LINK([
3614 #include <builtin.h>
3615         ],
3616         [two_arg_error_handler_t foo2 = lib_error_handler],
3617         [cf_cxx_library=yes
3618          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3619          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
3620         [cf_cxx_library=no])])
3621         LIBS="$cf_save"
3622         AC_MSG_RESULT($cf_cxx_library)
3623 fi
3624 ])dnl
3625 dnl ---------------------------------------------------------------------------
3626 dnl CF_GXX_VERSION version: 8 updated: 2017/02/11 14:48:57
3627 dnl --------------
3628 dnl Check for version of g++
3629 AC_DEFUN([CF_GXX_VERSION],[
3630 AC_REQUIRE([AC_PROG_CPP])
3631 GXX_VERSION=none
3632 if test "$GXX" = yes; then
3633         AC_MSG_CHECKING(version of ${CXX:-g++})
3634         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
3635         if test -z "$GXX_VERSION"
3636         then
3637                 GXX_VERSION=unknown
3638                 GXX=no
3639         fi
3640         AC_MSG_RESULT($GXX_VERSION)
3641 fi
3642 ])dnl
3643 dnl ---------------------------------------------------------------------------
3644 dnl CF_GXX_WARNINGS version: 11 updated: 2021/01/08 16:50:55
3645 dnl ---------------
3646 dnl Check if the compiler supports useful warning options.
3647 dnl
3648 dnl Most of gcc's options apply to g++, except:
3649 dnl     -Wbad-function-cast
3650 dnl     -Wmissing-declarations
3651 dnl     -Wnested-externs
3652 dnl
3653 dnl Omit a few (for now):
3654 dnl     -Winline
3655 dnl
3656 dnl Parameter:
3657 dnl     $1 is an optional list of g++ warning flags that a particular
3658 dnl             application might want to use, e.g., "no-unused" for
3659 dnl             -Wno-unused
3660 dnl Special:
3661 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
3662 dnl
3663 AC_DEFUN([CF_GXX_WARNINGS],
3664 [
3665
3666 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
3667 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
3668
3669 AC_REQUIRE([CF_GXX_VERSION])
3670
3671 AC_LANG_SAVE
3672 AC_LANG_CPLUSPLUS
3673
3674 cat > conftest.$ac_ext <<EOF
3675 #line __oline__ "configure"
3676 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
3677 EOF
3678
3679 if test "$INTEL_CPLUSPLUS" = yes
3680 then
3681 # The "-wdXXX" options suppress warnings:
3682 # remark #1419: external declaration in primary source file
3683 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3684 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3685 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
3686 # remark #193: zero used for undefined preprocessing identifier
3687 # remark #593: variable "curs_sb_left_arrow" was set but never used
3688 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
3689 # remark #869: parameter "tw" was never referenced
3690 # remark #981: operands are evaluated in unspecified order
3691 # warning #269: invalid format string conversion
3692
3693         AC_CHECKING([for $CC warning options])
3694         cf_save_CXXFLAGS="$CXXFLAGS"
3695         EXTRA_CXXFLAGS="-Wall"
3696         for cf_opt in \
3697                 wd1419 \
3698                 wd1682 \
3699                 wd1683 \
3700                 wd1684 \
3701                 wd193 \
3702                 wd279 \
3703                 wd593 \
3704                 wd810 \
3705                 wd869 \
3706                 wd981
3707         do
3708                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
3709                 if AC_TRY_EVAL(ac_compile); then
3710                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3711                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3712                 fi
3713         done
3714         CXXFLAGS="$cf_save_CXXFLAGS"
3715
3716 elif test "$GXX" = yes
3717 then
3718         AC_CHECKING([for $CXX warning options])
3719         cf_save_CXXFLAGS="$CXXFLAGS"
3720         EXTRA_CXXFLAGS="-W -Wall"
3721         cf_gxx_extra_warnings=""
3722         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
3723         case "$GXX_VERSION" in
3724         ([[1-2]].*)
3725                 ;;
3726         (*)
3727                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
3728                 ;;
3729         esac
3730         for cf_opt in \
3731                 Wabi \
3732                 fabi-version=0 \
3733                 Wextra \
3734                 Wignored-qualifiers \
3735                 Wlogical-op \
3736                 Woverloaded-virtual \
3737                 Wsign-promo \
3738                 Wsynth \
3739                 Wold-style-cast \
3740                 Wcast-align \
3741                 Wcast-qual \
3742                 Wpointer-arith \
3743                 Wshadow \
3744                 Wundef $cf_gxx_extra_warnings $1
3745         do
3746                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
3747                 if AC_TRY_EVAL(ac_compile); then
3748                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3749                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3750                 else
3751                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
3752                 fi
3753         done
3754         CXXFLAGS="$cf_save_CXXFLAGS"
3755 fi
3756
3757 rm -rf ./conftest*
3758 AC_LANG_RESTORE
3759 AC_SUBST(EXTRA_CXXFLAGS)
3760 ])dnl
3761 dnl ---------------------------------------------------------------------------
3762 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
3763 dnl ------------
3764 dnl Look for an instance of the Berkeley hashed database.
3765 dnl
3766 dnl $1 = optional parameter, to specify install-prefix for the database.
3767 AC_DEFUN([CF_HASHED_DB],
3768 [
3769 ifelse([$1],,,[
3770 case $1 in
3771 (yes|*able*)
3772         ;;
3773 (*)
3774         if test -d "$1" ; then
3775                 CF_ADD_INCDIR($1/include)
3776                 CF_ADD_LIBDIR($1/lib)
3777         else
3778                 case "$1" in
3779                 (./*|../*|/*)
3780                         AC_MSG_WARN(no such directory $1)
3781                         ;;
3782                 (*)
3783                         CF_FIND_SUB_INCDIR($1)
3784                         CF_FIND_SUB_LIBDIR($1)
3785                         ;;
3786                 esac
3787         fi
3788 esac
3789 ])
3790 AC_CHECK_HEADER(db.h,[
3791 CF_HASHED_DB_VERSION
3792 if test "$cf_cv_hashed_db_version" = unknown ; then
3793         AC_MSG_ERROR(Cannot determine version of db)
3794 else
3795         CF_HASHED_DB_LIBS
3796         if test "$cf_cv_hashed_db_libs" = unknown ; then
3797                 AC_MSG_ERROR(Cannot determine library for db)
3798         elif test "$cf_cv_hashed_db_libs" != default ; then
3799                 CF_ADD_LIB($cf_cv_hashed_db_libs)
3800         fi
3801 fi
3802 ],[
3803         AC_MSG_ERROR(Cannot find db.h)
3804 ])
3805 ])dnl
3806 dnl ---------------------------------------------------------------------------
3807 dnl CF_HASHED_DB_LIBS version: 10 updated: 2021/01/02 17:09:14
3808 dnl -----------------
3809 dnl Given that we have the header and version for hashed database, find the
3810 dnl library information.
3811 AC_DEFUN([CF_HASHED_DB_LIBS],
3812 [
3813 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
3814 cf_cv_hashed_db_libs=unknown
3815 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
3816 do
3817         cf_save_libs="$LIBS"
3818         if test -n "$cf_db_libs"; then
3819                 CF_ADD_LIB($cf_db_libs)
3820         fi
3821         CF_MSG_LOG(checking for library $cf_db_libs)
3822         AC_TRY_LINK([
3823 $ac_includes_default
3824 #include <db.h>
3825 ],[
3826         char *path = "/tmp/foo";
3827 #ifdef DB_VERSION_MAJOR
3828 #if DB_VERSION_MAJOR >= 4
3829         DB *result = 0;
3830         db_create(&result, NULL, 0);
3831         result->open(result,
3832                 NULL,
3833                 path,
3834                 path,
3835                 DB_HASH,
3836                 DB_CREATE,
3837                 0644);
3838 #elif DB_VERSION_MAJOR >= 3
3839         DB *result = 0;
3840         db_create(&result, NULL, 0);
3841         result->open(result,
3842                 path,
3843                 path,
3844                 DB_HASH,
3845                 DB_CREATE,
3846                 0644);
3847 #elif DB_VERSION_MAJOR >= 2
3848         DB *result = 0;
3849         db_open(path,
3850                 DB_HASH,
3851                 DB_CREATE,
3852                 0644,
3853                 (DB_ENV *) 0,
3854                 (DB_INFO *) 0,
3855                 &result);
3856 #endif /* DB_VERSION_MAJOR */
3857 #else
3858         DB *result = dbopen(path,
3859                      2,
3860                      0644,
3861                      DB_HASH,
3862                      0);
3863 #endif
3864         ${cf_cv_main_return:-return}(result != 0)
3865 ],[
3866         if test -n "$cf_db_libs" ; then
3867                 cf_cv_hashed_db_libs=$cf_db_libs
3868         else
3869                 cf_cv_hashed_db_libs=default
3870         fi
3871         LIBS="$cf_save_libs"
3872         break
3873 ])
3874         LIBS="$cf_save_libs"
3875 done
3876 ])
3877 ])dnl
3878 dnl ---------------------------------------------------------------------------
3879 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3880 dnl --------------------
3881 dnl Given that we have the header file for hashed database, find the version
3882 dnl information.
3883 AC_DEFUN([CF_HASHED_DB_VERSION],
3884 [
3885 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3886 cf_cv_hashed_db_version=unknown
3887
3888 for cf_db_version in 1 2 3 4 5 6
3889 do
3890         CF_MSG_LOG(checking for db version $cf_db_version)
3891         AC_TRY_COMPILE([
3892 $ac_includes_default
3893 #include <db.h>
3894
3895 #ifdef DB_VERSION_MAJOR
3896         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3897 #if $cf_db_version == DB_VERSION_MAJOR
3898         /* ok */
3899 #else
3900         make an error
3901 #endif
3902 #else
3903 #if $cf_db_version == 1
3904         /* ok: assuming this is DB 1.8.5 */
3905 #else
3906         make an error
3907 #endif
3908 #endif
3909 ],[DBT *foo = 0],[
3910         cf_cv_hashed_db_version=$cf_db_version
3911         break
3912         ])
3913 done
3914 ])
3915 ])dnl
3916 dnl ---------------------------------------------------------------------------
3917 dnl CF_HEADER_PATH version: 15 updated: 2021/01/01 13:31:04
3918 dnl --------------
3919 dnl Construct a search-list of directories for a nonstandard header-file
3920 dnl
3921 dnl Parameters
3922 dnl     $1 = the variable to return as result
3923 dnl     $2 = the package name
3924 AC_DEFUN([CF_HEADER_PATH],
3925 [
3926 $1=
3927
3928 # collect the current set of include-directories from compiler flags
3929 cf_header_path_list=""
3930 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3931         for cf_header_path in $CPPFLAGS $CFLAGS
3932         do
3933                 case "$cf_header_path" in
3934                 (-I*)
3935                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3936                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3937                         cf_header_path_list="$cf_header_path_list [$]$1"
3938                         ;;
3939                 esac
3940         done
3941 fi
3942
3943 # add the variations for the package we are looking for
3944 CF_SUBDIR_PATH($1,$2,include)
3945
3946 test "$includedir" != NONE && \
3947 test "$includedir" != "/usr/include" && \
3948 test -d "$includedir" && {
3949         test -d "$includedir" &&    $1="[$]$1 $includedir"
3950         test -d "$includedir/$2" && $1="[$]$1 $includedir/$2"
3951 }
3952
3953 test "$oldincludedir" != NONE && \
3954 test "$oldincludedir" != "/usr/include" && \
3955 test -d "$oldincludedir" && {
3956         test -d "$oldincludedir"    && $1="[$]$1 $oldincludedir"
3957         test -d "$oldincludedir/$2" && $1="[$]$1 $oldincludedir/$2"
3958 }
3959
3960 $1="[$]$1 $cf_header_path_list"
3961 ])dnl
3962 dnl ---------------------------------------------------------------------------
3963 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
3964 dnl ---------------
3965 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3966 AC_DEFUN([CF_HELP_MESSAGE],
3967 [CF_ACVERSION_CHECK(2.53,[],[
3968 AC_DIVERT_HELP($1)])dnl
3969 ])dnl
3970 dnl ---------------------------------------------------------------------------
3971 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3972 dnl ---------------
3973 dnl Construct the list of include-options according to whether we're building
3974 dnl in the source directory or using '--srcdir=DIR' option.
3975 AC_DEFUN([CF_INCLUDE_DIRS],
3976 [
3977 if test "$srcdir" != "."; then
3978         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3979 fi
3980 CPPFLAGS="-I../include $CPPFLAGS"
3981 if test "$srcdir" != "."; then
3982         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3983 fi
3984 CPPFLAGS="-I. $CPPFLAGS"
3985 AC_SUBST(CPPFLAGS)
3986 ])dnl
3987 dnl ---------------------------------------------------------------------------
3988 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
3989 dnl ---------------
3990 dnl prompt for/fill-in useful install-program options
3991 AC_DEFUN([CF_INSTALL_OPTS],
3992 [
3993 CF_INSTALL_OPT_S
3994 CF_INSTALL_OPT_P
3995 CF_INSTALL_OPT_O
3996 ])dnl
3997 dnl ---------------------------------------------------------------------------
3998 dnl CF_INSTALL_OPT_O version: 3 updated: 2020/12/31 20:19:42
3999 dnl ----------------
4000 dnl Almost all "install" programs default to the current user's ownership.
4001 dnl Almost - MINIX is an exception.
4002 AC_DEFUN([CF_INSTALL_OPT_O],
4003 [
4004 AC_MSG_CHECKING(if install needs to be told about ownership)
4005 case `$ac_config_guess` in
4006 (*minix)
4007         with_install_o=yes
4008         ;;
4009 (*)
4010         with_install_o=no
4011         ;;
4012 esac
4013
4014 AC_MSG_RESULT($with_install_o)
4015 if test "x$with_install_o" = xyes
4016 then
4017         INSTALL_OPT_O="`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`"
4018 else
4019         INSTALL_OPT_O=
4020 fi
4021
4022 AC_SUBST(INSTALL_OPT_O)
4023 ])dnl
4024 dnl ---------------------------------------------------------------------------
4025 dnl CF_INSTALL_OPT_P version: 3 updated: 2021/01/01 13:31:04
4026 dnl ----------------
4027 dnl Some install-programs accept a "-p" option to preserve file modification
4028 dnl timestamps.  That can be useful as an install option, as well as a way to
4029 dnl avoid the need for ranlib after copying a static archive.
4030 AC_DEFUN([CF_INSTALL_OPT_P],
4031 [
4032 : "${INSTALL:=install}"
4033 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
4034         rm -rf ./conftest*
4035         date >conftest.in
4036         mkdir conftest.out
4037         sleep 3
4038         if $INSTALL -p conftest.in conftest.out 2>/dev/null
4039         then
4040                 if test -f conftest.out/conftest.in
4041                 then
4042                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
4043                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
4044                         if test -s conftest.err
4045                         then
4046                                 cf_cv_install_p=no
4047                         else
4048                                 cf_cv_install_p=yes
4049                         fi
4050                 else
4051                         cf_cv_install_p=no
4052                 fi
4053         else
4054                 cf_cv_install_p=no
4055         fi
4056         rm -rf ./conftest*
4057 ])
4058 ])dnl
4059 dnl ---------------------------------------------------------------------------
4060 dnl CF_INSTALL_OPT_S version: 3 updated: 2021/01/05 19:23:48
4061 dnl ----------------
4062 dnl By default, we should strip executables which are installed, but leave the
4063 dnl ability to suppress that for unit-testing.
4064 AC_DEFUN([CF_INSTALL_OPT_S],
4065 [
4066 AC_MSG_CHECKING(if you want to install stripped executables)
4067 CF_ARG_DISABLE(stripping,
4068         [  --disable-stripping     do not strip (debug info) installed executables],
4069         [enable_stripping=no],
4070         [enable_stripping=yes])
4071 AC_MSG_RESULT($enable_stripping)
4072
4073 if test "$enable_stripping" = yes
4074 then
4075         INSTALL_OPT_S="-s"
4076 else
4077         INSTALL_OPT_S=
4078 fi
4079 AC_SUBST(INSTALL_OPT_S)
4080 ])dnl
4081 dnl ---------------------------------------------------------------------------
4082 dnl CF_INTEL_COMPILER version: 8 updated: 2021/01/01 16:53:59
4083 dnl -----------------
4084 dnl Check if the given compiler is really the Intel compiler for Linux.  It
4085 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
4086 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
4087 dnl
4088 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
4089 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
4090 dnl the wrappers for gcc and g++ warnings.
4091 dnl
4092 dnl $1 = GCC (default) or GXX
4093 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
4094 dnl $3 = CFLAGS (default) or CXXFLAGS
4095 AC_DEFUN([CF_INTEL_COMPILER],[
4096 AC_REQUIRE([AC_CANONICAL_HOST])
4097 ifelse([$2],,INTEL_COMPILER,[$2])=no
4098
4099 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
4100         case "$host_os" in
4101         (linux*|gnu*)
4102                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
4103                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
4104                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
4105                 AC_TRY_COMPILE([],[
4106 #ifdef __INTEL_COMPILER
4107 #else
4108 make an error
4109 #endif
4110 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
4111 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
4112 ],[])
4113                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
4114                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
4115                 ;;
4116         esac
4117 fi
4118 ])dnl
4119 dnl ---------------------------------------------------------------------------
4120 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
4121 dnl ----------
4122 dnl Check if we have either a function or macro for 'isascii()'.
4123 AC_DEFUN([CF_ISASCII],
4124 [
4125 AC_MSG_CHECKING(for isascii)
4126 AC_CACHE_VAL(cf_cv_have_isascii,[
4127         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
4128         [cf_cv_have_isascii=yes],
4129         [cf_cv_have_isascii=no])
4130 ])dnl
4131 AC_MSG_RESULT($cf_cv_have_isascii)
4132 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
4133 ])dnl
4134 dnl ---------------------------------------------------------------------------
4135 dnl CF_LARGEFILE version: 12 updated: 2020/03/19 20:23:48
4136 dnl ------------
4137 dnl Add checks for large file support.
4138 AC_DEFUN([CF_LARGEFILE],[
4139 ifdef([AC_FUNC_FSEEKO],[
4140         AC_SYS_LARGEFILE
4141         if test "$enable_largefile" != no ; then
4142         AC_FUNC_FSEEKO
4143
4144         # Normally we would collect these definitions in the config.h,
4145         # but (like _XOPEN_SOURCE), some environments rely on having these
4146         # defined before any of the system headers are included.  Another
4147         # case comes up with C++, e.g., on AIX the compiler compiles the
4148         # header files by themselves before looking at the body files it is
4149         # told to compile.  For ncurses, those header files do not include
4150         # the config.h
4151         if test "$ac_cv_sys_large_files" != no
4152         then
4153                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
4154         fi
4155         if test "$ac_cv_sys_largefile_source" != no
4156         then
4157                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
4158         fi
4159         if test "$ac_cv_sys_file_offset_bits" != no
4160         then
4161                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
4162         fi
4163
4164         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
4165                 AC_TRY_COMPILE([
4166 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
4167 #include <sys/types.h>
4168 #include <dirent.h>
4169                 ],[
4170                 /* if transitional largefile support is setup, this is true */
4171                 extern struct dirent64 * readdir(DIR *);
4172                 struct dirent64 *x = readdir((DIR *)0);
4173                 struct dirent *y = readdir((DIR *)0);
4174                 int z = x - y;
4175                 (void)z;
4176                 ],
4177                 [cf_cv_struct_dirent64=yes],
4178                 [cf_cv_struct_dirent64=no])
4179         ])
4180         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
4181         fi
4182 ])
4183 ])
4184 dnl ---------------------------------------------------------------------------
4185 dnl CF_LDFLAGS_STATIC version: 14 updated: 2021/01/02 17:09:14
4186 dnl -----------------
4187 dnl Check for compiler/linker flags used to temporarily force usage of static
4188 dnl libraries.  This depends on the compiler and platform.  Use this to help
4189 dnl ensure that the linker picks up a given library based on its position in
4190 dnl the list of linker options and libraries.
4191 AC_DEFUN([CF_LDFLAGS_STATIC],[
4192
4193 if test "$GCC" = yes ; then
4194         case "$cf_cv_system_name" in
4195         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
4196                 LDFLAGS_STATIC=
4197                 LDFLAGS_SHARED=
4198                 ;;
4199         (*)     # normally, except when broken
4200                 LDFLAGS_STATIC=-static
4201                 LDFLAGS_SHARED=-dynamic
4202                 ;;
4203         esac
4204 else
4205         case "$cf_cv_system_name" in
4206         (aix[[4-7]]*)   # from ld manpage
4207                 LDFLAGS_STATIC=-bstatic
4208                 LDFLAGS_SHARED=-bdynamic
4209                 ;;
4210         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
4211                 # We could also use just "archive" and "shared".
4212                 LDFLAGS_STATIC=-Wl,-a,archive_shared
4213                 LDFLAGS_SHARED=-Wl,-a,shared_archive
4214                 ;;
4215         (irix*)         # from ld manpage IRIX64
4216                 LDFLAGS_STATIC=-Bstatic
4217                 LDFLAGS_SHARED=-Bdynamic
4218                 ;;
4219         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
4220                 # alternative "-oldstyle_liblookup" (not in cc manpage)
4221                 LDFLAGS_STATIC=-noso
4222                 LDFLAGS_SHARED=-so_archive
4223                 ;;
4224         (solaris2*)
4225                 LDFLAGS_STATIC=-Bstatic
4226                 LDFLAGS_SHARED=-Bdynamic
4227                 ;;
4228         esac
4229 fi
4230
4231 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
4232 then
4233         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
4234
4235         rm -f libconftest.a
4236         cat >conftest.$ac_ext <<EOF
4237 #line __oline__ "configure"
4238 #include <stdio.h>
4239 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
4240 EOF
4241         if AC_TRY_EVAL(ac_compile) ; then
4242                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
4243                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
4244         fi
4245         rm -f conftest.*
4246
4247         cf_save_LIBS="$LIBS"
4248
4249         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
4250         AC_TRY_LINK([
4251 #line __oline__ "configure"
4252 #include <stdio.h>
4253 int cf_ldflags_static(FILE *fp);
4254 ],[
4255         return cf_ldflags_static(stdin);
4256 ],[
4257         # some linkers simply ignore the -dynamic
4258         case x`file "conftest$ac_exeext" 2>/dev/null` in
4259         (*static*)
4260                 cf_ldflags_static=no
4261                 ;;
4262         (*)
4263                 cf_ldflags_static=yes
4264                 ;;
4265         esac
4266 ],[cf_ldflags_static=no])
4267
4268         rm -f libconftest.*
4269         LIBS="$cf_save_LIBS"
4270
4271         AC_MSG_RESULT($cf_ldflags_static)
4272
4273         if test "$cf_ldflags_static" != yes
4274         then
4275                 LDFLAGS_STATIC=
4276                 LDFLAGS_SHARED=
4277         fi
4278 else
4279         LDFLAGS_STATIC=
4280         LDFLAGS_SHARED=
4281 fi
4282
4283 AC_SUBST(LDFLAGS_STATIC)
4284 AC_SUBST(LDFLAGS_SHARED)
4285 ])
4286 dnl ---------------------------------------------------------------------------
4287 dnl CF_LD_RPATH_OPT version: 9 updated: 2021/01/01 13:31:04
4288 dnl ---------------
4289 dnl For the given system and compiler, find the compiler flags to pass to the
4290 dnl loader to use the "rpath" feature.
4291 AC_DEFUN([CF_LD_RPATH_OPT],
4292 [
4293 AC_REQUIRE([CF_CHECK_CACHE])
4294
4295 LD_RPATH_OPT=
4296 if test "x$cf_cv_enable_rpath" != xno
4297 then
4298         AC_MSG_CHECKING(for an rpath option)
4299         case "$cf_cv_system_name" in
4300         (irix*)
4301                 if test "$GCC" = yes; then
4302                         LD_RPATH_OPT="-Wl,-rpath,"
4303                 else
4304                         LD_RPATH_OPT="-rpath "
4305                 fi
4306                 ;;
4307         (linux*|gnu*|k*bsd*-gnu|freebsd*)
4308                 LD_RPATH_OPT="-Wl,-rpath,"
4309                 ;;
4310         (openbsd[[2-9]].*|mirbsd*)
4311                 LD_RPATH_OPT="-Wl,-rpath,"
4312                 ;;
4313         (dragonfly*)
4314                 LD_RPATH_OPT="-rpath "
4315                 ;;
4316         (netbsd*)
4317                 LD_RPATH_OPT="-Wl,-rpath,"
4318                 ;;
4319         (osf*|mls+*)
4320                 LD_RPATH_OPT="-rpath "
4321                 ;;
4322         (solaris2*)
4323                 LD_RPATH_OPT="-R"
4324                 ;;
4325         (*)
4326                 ;;
4327         esac
4328         AC_MSG_RESULT($LD_RPATH_OPT)
4329
4330         case "x$LD_RPATH_OPT" in
4331         (x-R*)
4332                 AC_MSG_CHECKING(if we need a space after rpath option)
4333                 cf_save_LIBS="$LIBS"
4334                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
4335                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
4336                 LIBS="$cf_save_LIBS"
4337                 AC_MSG_RESULT($cf_rpath_space)
4338                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
4339                 ;;
4340         esac
4341 fi
4342 ])dnl
4343 dnl ---------------------------------------------------------------------------
4344 dnl CF_LD_SEARCHPATH version: 4 updated: 2022/08/27 15:43:08
4345 dnl ----------------
4346 dnl Try to obtain the linker's search-path, for use in scripts.
4347 dnl
4348 dnl Ignore LD_LIBRARY_PATH, etc.
4349 AC_DEFUN([CF_LD_SEARCHPATH],[
4350 AC_CACHE_CHECK(for linker search path,cf_cv_ld_searchpath,[
4351
4352 if test "$cross_compiling" != yes ; then
4353
4354 # GNU binutils' ld does not involve permissions which may stop ldconfig.
4355 cf_pathlist=`${LD:-ld} --verbose 2>/dev/null | grep SEARCH_DIR | sed -e 's,SEARCH_DIR[[("=]][[("=]]*,,g' -e 's/"[[)]];//gp' | sort -u`
4356
4357 # The -NX options tell newer versions of Linux ldconfig to not attempt to
4358 # update the cache, which makes it run faster.
4359 test -z "$cf_pathlist" && \
4360         cf_pathlist=`(ldconfig -NX -v) 2>/dev/null | sed -e '/^[[       ]]/d' -e 's/:$//' | sort -u`
4361
4362 test -z "$cf_pathlist" &&
4363         cf_pathlist=`(ldconfig -v) 2>/dev/null | sed -n -e '/^[[        ]]/d' -e 's/:$//p' | sort -u`
4364
4365 # This works with OpenBSD 6.5, which lists only filenames
4366 test -z "$cf_pathlist" &&
4367         cf_pathlist=`(ldconfig -v) 2>/dev/null | sed -n -e 's,^Adding \(.*\)/.*[$],\1,p' | sort -u`
4368
4369 if test -z "$cf_pathlist"
4370 then
4371         # dyld default path with MacOS
4372         if test -f /usr/bin/otool && test "x`uname -s`" = xDarwin
4373         then
4374                 # do this to bypass check
4375                 cf_cv_ld_searchpath='$HOME/lib'
4376                 cf_pathlist="/usr/local/lib /lib /usr/lib"
4377         fi
4378 fi
4379
4380 if test -z "$cf_pathlist"
4381 then
4382         # Solaris is "SunOS"
4383         if test -f /usr/bin/isainfo && test "x`uname -s`" = xSunOS
4384         then
4385                 case x`(isainfo -b)` in
4386                 (x64)
4387                         cf_pathlist="$cf_pathlist /lib/64 /usr/lib/64"
4388                         ;;
4389                 (x32)
4390                         test -d /usr/ccs/lib && cf_pathlist="$cf_pathlist /usr/ccs/lib"
4391                         cf_pathlist="$cf_pathlist /lib /usr/lib"
4392                         ;;
4393                 (*)
4394                         AC_MSG_WARN(problem with Solaris architecture)
4395                         ;;
4396                 esac
4397         fi
4398 fi
4399
4400 if test -z "$cf_pathlist"
4401 then
4402         # HP-UX
4403         if test x"`uname -s`" = xHP-UX
4404         then
4405                 case x`getconf LONG_BIT` in
4406                 (x64)
4407                         cf_pathlist="/usr/lib/hpux64"
4408                         ;;
4409                 (x*)
4410                         cf_pathlist="/usr/lib/hpux32"
4411                         ;;
4412                 esac
4413         fi
4414 fi
4415
4416 fi
4417
4418 # If nothing else, assume it is conventional
4419 test -z "$cf_pathlist" && cf_pathlist="/usr/lib /lib"
4420
4421 # Finally, check that this is only directories
4422 for cf_path in [$]0 $cf_pathlist
4423 do
4424         if test -d "$cf_path"; then
4425                 test -n "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath="${cf_cv_ld_searchpath} "
4426                 cf_cv_ld_searchpath="${cf_cv_ld_searchpath}${cf_path}"
4427         fi
4428 done
4429
4430 # Ensure that it is nonempty
4431 test -z "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath=/usr/lib
4432 ])
4433
4434 LD_SEARCHPATH=`echo "$cf_cv_ld_searchpath"|sed -e 's/ /|/g'`
4435 AC_SUBST(LD_SEARCHPATH)
4436 ])dnl
4437 dnl ---------------------------------------------------------------------------
4438 dnl CF_LIBRARY_PATH version: 11 updated: 2021/01/01 13:31:04
4439 dnl ---------------
4440 dnl Construct a search-list of directories for a nonstandard library-file
4441 dnl
4442 dnl Parameters
4443 dnl     $1 = the variable to return as result
4444 dnl     $2 = the package name
4445 AC_DEFUN([CF_LIBRARY_PATH],
4446 [
4447 $1=
4448 cf_library_path_list=""
4449 if test -n "${LDFLAGS}${LIBS}" ; then
4450         for cf_library_path in $LDFLAGS $LIBS
4451         do
4452                 case "$cf_library_path" in
4453                 (-L*)
4454                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
4455                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
4456                         cf_library_path_list="$cf_library_path_list [$]$1"
4457                         ;;
4458                 esac
4459         done
4460 fi
4461
4462 CF_SUBDIR_PATH($1,$2,lib)
4463
4464 $1="$cf_library_path_list [$]$1"
4465 ])dnl
4466 dnl ---------------------------------------------------------------------------
4467 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
4468 dnl ------------------
4469 AC_DEFUN([CF_LIBTOOL_VERSION],[
4470 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
4471 then
4472         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
4473 else
4474         cf_cv_libtool_version=
4475 fi
4476 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
4477 ])dnl
4478 dnl ---------------------------------------------------------------------------
4479 dnl CF_LIB_PREFIX version: 14 updated: 2021/01/01 13:31:04
4480 dnl -------------
4481 dnl Compute the library-prefix for the given host system
4482 dnl $1 = variable to set
4483 define([CF_LIB_PREFIX],
4484 [
4485         case "$cf_cv_system_name" in
4486         (OS/2*|os2*)
4487                 if test "$DFT_LWR_MODEL" = libtool; then
4488                         LIB_PREFIX='lib'
4489                 else
4490                         LIB_PREFIX=''
4491                 fi
4492                 ;;
4493         (*-msvc*)
4494                 LIB_PREFIX=''
4495                 ;;
4496         (*)     LIB_PREFIX='lib'
4497                 ;;
4498         esac
4499 ifelse($1,,,[$1=$LIB_PREFIX])
4500         AC_SUBST(LIB_PREFIX)
4501 ])dnl
4502 dnl ---------------------------------------------------------------------------
4503 dnl CF_LIB_RULES version: 98 updated: 2023/01/07 16:32:06
4504 dnl ------------
4505 dnl Append definitions and rules for the given models to the subdirectory
4506 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
4507 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
4508 dnl the corresponding makefile to list the models that we'll generate.
4509 dnl
4510 dnl For shared libraries, make a list of symbolic links to construct when
4511 dnl generating each library.  The convention used for Linux is the simplest
4512 dnl one:
4513 dnl     lib<name>.so    ->
4514 dnl     lib<name>.so.<major>    ->
4515 dnl     lib<name>.so.<maj>.<minor>
4516 dnl
4517 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
4518 AC_DEFUN([CF_LIB_RULES],
4519 [AC_REQUIRE([AC_PROG_FGREP])dnl
4520 AC_REQUIRE([CF_MAKE_PHONY])dnl
4521
4522 cf_prefix=$LIB_PREFIX
4523 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
4524
4525 case "$cf_cv_shlib_version" in
4526 (cygdll|msysdll|mingw|msvcdll)
4527         TINFO_NAME=$TINFO_ARG_SUFFIX
4528         TINFO_SUFFIX=.dll
4529         ;;
4530 esac
4531
4532 if test -n "$TINFO_SUFFIX" ; then
4533         case "$TINFO_SUFFIX" in
4534         (tw*)
4535                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
4536                 TINFO_SUFFIX=`echo "$TINFO_SUFFIX" | sed 's/^tw'$EXTRA_SUFFIX'//'`
4537                 ;;
4538         (t*)
4539                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
4540                 TINFO_SUFFIX=`echo "$TINFO_SUFFIX" | sed 's/^t'$EXTRA_SUFFIX'//'`
4541                 ;;
4542         (w*)
4543                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
4544                 TINFO_SUFFIX=`echo "$TINFO_SUFFIX" | sed 's/^w'$EXTRA_SUFFIX'//'`
4545                 ;;
4546         esac
4547 fi
4548
4549 for cf_dir in $SRC_SUBDIRS
4550 do
4551         if test ! -d "$srcdir/$cf_dir" ; then
4552                 continue
4553         elif test -f "$srcdir/$cf_dir/modules" ; then
4554
4555                 SHARED_LIB=
4556                 Libs_To_Make=
4557                 cf_awk_program=
4558                 if test -n "${cf_cv_abi_default}" && test "x${cf_cv_abi_default}" != "x5"
4559                 then
4560                         cf_awk_program="$cf_awk_program\
4561 /deprecated in ABI${cf_cv_abi_default}/ { next; }\
4562 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_default}\"); }\
4563 "
4564                 fi
4565
4566                 if test "x$WILDCARD_SYMS" = xno
4567                 then
4568                         cf_awk_program="$cf_awk_program\
4569 /[[     ]]_\\*;/ { skip=1; next; }\
4570 "
4571                 fi
4572
4573                 if test "x$cf_awk_program" != "x"
4574                 then
4575                         cat >>$cf_dir/Makefile <<CF_EOF
4576
4577 # Generated by CF_LIB_RULES
4578 resulting.map: $UNALTERED_SYMS
4579         $AWK 'BEGIN { skip = 1; last=""; } \
4580 $cf_awk_program \
4581 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
4582  skip = 0; last = \[$]\[$]0; } \
4583 END { print last; }' < "$UNALTERED_SYMS" >\[$]@
4584
4585 distclean::
4586         rm -f resulting.map
4587 CF_EOF
4588                 fi
4589
4590                 for cf_item in $cf_LIST_MODELS
4591                 do
4592                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4593                         if test "$cf_dir" = "c++"
4594                         then
4595                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4596                         else
4597                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4598                         fi
4599                         test -z "$cf_libname" && cf_libname="$cf_dir"
4600                         if test "$cf_item" = shared ; then
4601                                 if test -n "${LIB_SUFFIX}"
4602                                 then
4603                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4604                                 else
4605                                         cf_shared_suffix="$cf_suffix"
4606                                 fi
4607                                 if test "$cf_cv_do_symlinks" = yes ; then
4608                                         cf_version_name=
4609
4610                                         case "$cf_cv_shlib_version" in
4611                                         (rel)
4612                                                 cf_version_name=REL_VERSION
4613                                                 ;;
4614                                         (abi)
4615                                                 cf_version_name=ABI_VERSION
4616                                                 ;;
4617                                         esac
4618
4619                                         if test -n "$cf_version_name"
4620                                         then
4621                                                 case "$cf_cv_system_name" in
4622                                                 (darwin*)
4623                                                         # "w", etc?
4624                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
4625                                                         ;;
4626                                                 (*)
4627                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
4628                                                         ;;
4629                                                 esac
4630                                         fi
4631                                         if test -n "${USE_LIB_SUFFIX}"
4632                                         then
4633                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4634                                         else
4635                                                 cf_shared_suffix="$cf_suffix"
4636                                         fi
4637                                 fi
4638                                 # cygwin needs import library, and has unique naming convention
4639                                 # use autodetected ${cf_prefix} for import lib and static lib, but
4640                                 # use 'cyg' prefix for shared lib.
4641                                 case "$cf_cv_shlib_version" in
4642                                 (cygdll)
4643                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4644                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
4645                                         ;;
4646                                 (msysdll)
4647                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4648                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
4649                                         ;;
4650                                 (mingw)
4651                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4652                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
4653                                         ;;
4654                                 (msvcdll)
4655                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4656                                         cf_add_lib="../lib/${cf_libname}${cf_cygsuf}"
4657                                         ;;
4658                                 (*)
4659                                         cf_add_lib=
4660                                         ;;
4661                                 esac
4662                                 if test -n "$cf_add_lib"
4663                                 then
4664                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4665                                         continue
4666                                 fi
4667                         fi
4668                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
4669                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4670                 done
4671
4672                 if test "$cf_dir" = ncurses ; then
4673                         cf_subsets="$LIB_SUBSETS"
4674                         cf_r_parts="$cf_subsets"
4675                         cf_liblist="$Libs_To_Make"
4676
4677                         while test -n "$cf_r_parts"
4678                         do
4679                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
4680                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
4681                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
4682                                         cf_add_lib=
4683                                         case "$cf_l_parts" in
4684                                         (*termlib*)
4685                                                 cf_add_lib=`echo "$cf_liblist" |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
4686                                                 ;;
4687                                         (*ticlib*)
4688                                                 cf_add_lib=`echo "$cf_liblist" |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
4689                                                 ;;
4690                                         (*)
4691                                                 break
4692                                                 ;;
4693                                         esac
4694                                         if test -n "$cf_add_lib"; then
4695                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
4696                                         fi
4697                                 else
4698                                         break
4699                                 fi
4700                         done
4701                 else
4702                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
4703                 fi
4704
4705                 if test "$cf_dir" = c++; then
4706                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
4707                                 cf_list=
4708                                 for cf_item in $Libs_To_Make
4709                                 do
4710                                         case "$cf_item" in
4711                                         (*.a)
4712                                                 ;;
4713                                         (*)
4714                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
4715                                                 ;;
4716                                         esac
4717                                         for cf_test in $cf_list
4718                                         do
4719                                                 if test "$cf_test" = "$cf_item"
4720                                                 then
4721                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
4722                                                         cf_item=
4723                                                         break
4724                                                 fi
4725                                         done
4726                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
4727                                 done
4728                                 Libs_To_Make="$cf_list"
4729                         fi
4730                 fi
4731
4732                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
4733                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
4734                         "$cf_dir/Makefile" >$cf_dir/Makefile.out
4735                 mv "$cf_dir/Makefile.out" "$cf_dir/Makefile"
4736
4737                 $AWK -f "$srcdir/mk-0th.awk" \
4738                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
4739                         "$srcdir/$cf_dir/modules" >>$cf_dir/Makefile
4740
4741                 for cf_subset in $cf_subsets
4742                 do
4743                         cf_subdirs=
4744                         for cf_item in $cf_LIST_MODELS
4745                         do
4746
4747                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
4748                         CF_UPPER(cf_ITEM,$cf_item)
4749
4750                         CXX_MODEL=$cf_ITEM
4751                         if test "$CXX_MODEL" = SHARED; then
4752                                 case "$cf_cv_shlib_version" in
4753                                 (cygdll|msysdll|mingw|msvcdll)
4754                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
4755                                         with_shared_cxx=yes
4756                                         ;;
4757                                 (*)
4758                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
4759                                         ;;
4760                                 esac
4761                         fi
4762
4763                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4764                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
4765
4766                         # Test for case where we build libtinfo with a different name.
4767                         cf_libname=$cf_dir
4768                         if test "$cf_dir" = ncurses ; then
4769                                 case "$cf_subset" in
4770                                 (*base*)
4771                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
4772                                         ;;
4773                                 (*termlib*)
4774                                         cf_libname=$TINFO_LIB_SUFFIX
4775                                         ;;
4776                                 (ticlib*)
4777                                         cf_libname=$TICS_LIB_SUFFIX
4778                                         ;;
4779                                 esac
4780                         elif test "$cf_dir" = c++ ; then
4781                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4782                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4783                         else
4784                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4785                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4786                         fi
4787                         if test -n "${USE_ARG_SUFFIX}" ; then
4788                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
4789                                 cf_suffix=`echo "$cf_suffix" |sed -e "s%^${USE_LIB_SUFFIX}%%"`
4790                         fi
4791
4792                         # These dependencies really are for development, not
4793                         # builds, but they are useful in porting, too.
4794                         cf_depend="../include/ncurses_cfg.h"
4795                         if test "$srcdir" = "."; then
4796                                 cf_reldir="."
4797                         else
4798                                 cf_reldir="\${srcdir}"
4799                         fi
4800
4801                         if test -f "$srcdir/$cf_dir/$cf_dir.priv.h" ; then
4802                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
4803                         elif test -f "$srcdir/$cf_dir/curses.priv.h" ; then
4804                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
4805                         fi
4806
4807                         cf_dir_suffix=
4808                         old_cf_suffix="$cf_suffix"
4809                         if test "$cf_cv_shlib_version_infix" = yes ; then
4810                         if test -n "$USE_LIB_SUFFIX" ; then
4811                                 case "$USE_LIB_SUFFIX" in
4812                                 (tw*)
4813                                         cf_libname=`echo "$cf_libname" | sed 's/tw'$EXTRA_SUFFIX'$//'`
4814                                         cf_suffix=`echo "$cf_suffix" | sed 's/^tw'$EXTRA_SUFFIX'//'`
4815                                         cf_dir_suffix=tw$EXTRA_SUFFIX
4816                                         ;;
4817                                 (t*)
4818                                         cf_libname=`echo "$cf_libname" | sed 's/t'$EXTRA_SUFFIX'$//'`
4819                                         cf_suffix=`echo "$cf_suffix" | sed 's/^t'$EXTRA_SUFFIX'//'`
4820                                         cf_dir_suffix=t$EXTRA_SUFFIX
4821                                         ;;
4822                                 (w*)
4823                                         cf_libname=`echo "$cf_libname" | sed 's/w'$EXTRA_SUFFIX'$//'`
4824                                         cf_suffix=`echo "$cf_suffix" | sed 's/^w'$EXTRA_SUFFIX'//'`
4825                                         cf_dir_suffix=w$EXTRA_SUFFIX
4826                                         ;;
4827                                 (*)
4828                                         cf_libname=`echo "$cf_libname" | sed 's/'$EXTRA_SUFFIX'$//'`
4829                                         cf_suffix=`echo "$cf_suffix" | sed 's/^'$EXTRA_SUFFIX'//'`
4830                                         cf_dir_suffix=$EXTRA_SUFFIX
4831                                         ;;
4832                                 esac
4833                         fi
4834                         fi
4835
4836                         $AWK -f "$srcdir/mk-1st.awk" \
4837                                 name=${cf_libname}${cf_dir_suffix} \
4838                                 traces=$LIB_TRACING \
4839                                 MODEL=$cf_ITEM \
4840                                 CXX_MODEL=$CXX_MODEL \
4841                                 LIB_SUFFIX=$LIB_SUFFIX \
4842                                 USE_LIB_SUFFIX=$USE_LIB_SUFFIX \
4843                                 make_phony="${cf_cv_make_PHONY:-no}" \
4844                                 model=$cf_subdir \
4845                                 prefix=$cf_prefix \
4846                                 suffix=$cf_suffix \
4847                                 subset=$cf_subset \
4848                                 driver=$cf_cv_term_driver \
4849                                 SymLink="$LN_S" \
4850                                 TermlibRoot=$TINFO_NAME \
4851                                 TermlibSuffix=$TINFO_SUFFIX \
4852                                 ShlibVer=$cf_cv_shlib_version \
4853                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
4854                                 ReLink=${cf_cv_do_relink:-no} \
4855                                 ReRanlib=${cf_cv_do_reranlib:-yes} \
4856                                 DoLinks=$cf_cv_do_symlinks \
4857                                 rmSoLocs=$cf_cv_rm_so_locs \
4858                                 ldconfig="$LDCONFIG" \
4859                                 overwrite=$WITH_OVERWRITE \
4860                                 depend="$cf_depend" \
4861                                 host="$host" \
4862                                 libtool_version="$LIBTOOL_VERSION" \
4863                                 "$srcdir/$cf_dir/modules" >>$cf_dir/Makefile
4864
4865                         cf_suffix="$old_cf_suffix"
4866
4867                         for cf_subdir2 in $cf_subdirs lib
4868                         do
4869                                 test "$cf_subdir" = "$cf_subdir2" && break
4870                         done
4871                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
4872                         $AWK -f "$srcdir/mk-2nd.awk" \
4873                                 name=$cf_dir \
4874                                 traces=$LIB_TRACING \
4875                                 MODEL=$cf_ITEM \
4876                                 model=$cf_subdir \
4877                                 subset=$cf_subset \
4878                                 srcdir=$srcdir \
4879                                 echo=$WITH_ECHO \
4880                                 crenames=$cf_cv_prog_CC_c_o \
4881                                 cxxrenames=$cf_cv_prog_CXX_c_o \
4882                                 "$srcdir/$cf_dir/modules" >>$cf_dir/Makefile
4883                         cf_subdirs="$cf_subdirs $cf_subdir"
4884                         done
4885                 done
4886         fi
4887
4888         echo '  ( cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@ )' >>Makefile
4889 done
4890
4891 echo >> Makefile
4892 echo '# generated by CF_LIB_RULES' >> Makefile
4893
4894 if test "x$cf_cv_make_PHONY" = xyes ; then
4895         cat >> Makefile <<-CF_EOF
4896
4897         .PHONY :        libs
4898         .PHONY :        lintlib
4899         .PHONY :        install.includes
4900         .PHONY :        uninstall.includes
4901         .PHONY :        install.libs
4902         .PHONY :        uninstall.libs
4903 CF_EOF
4904 fi
4905
4906 for cf_dir in $SRC_SUBDIRS
4907 do
4908         if test ! -d "$srcdir/$cf_dir" ; then
4909                 continue
4910         fi
4911
4912         if test -f "$cf_dir/Makefile" ; then
4913                 case "$cf_dir" in
4914                 (Ada95)
4915                         echo 'libs \' >> Makefile
4916                         echo 'install.libs \' >> Makefile
4917                         echo 'uninstall.libs ::' >> Makefile
4918                         echo '  ( cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@ )' >> Makefile
4919                         ;;
4920                 esac
4921         fi
4922
4923         if test -f "$srcdir/$cf_dir/modules" ; then
4924
4925                 if test "x$cf_cv_make_PHONY" = xyes ; then
4926                         cat >> Makefile <<-CF_EOF
4927
4928                         .PHONY :        install.$cf_dir
4929                         .PHONY :        uninstall.$cf_dir
4930 CF_EOF
4931                 fi
4932
4933                 echo >> Makefile
4934                 if test -f "$srcdir/$cf_dir/headers" ; then
4935 cat >> Makefile <<CF_EOF
4936 install.includes \\
4937 uninstall.includes \\
4938 CF_EOF
4939                 fi
4940
4941 cat >> Makefile <<CF_EOF
4942 lint \\
4943 libs \\
4944 lintlib \\
4945 install.libs \\
4946 uninstall.libs \\
4947 install.$cf_dir \\
4948 uninstall.$cf_dir ::
4949         ( cd "$cf_dir" && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4950 CF_EOF
4951         elif test -f "$srcdir/$cf_dir/headers" ; then
4952 cat >> Makefile <<CF_EOF
4953
4954 libs \\
4955 install.libs \\
4956 uninstall.libs \\
4957 install.includes \\
4958 uninstall.includes ::
4959         ( cd "$cf_dir" && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4960 CF_EOF
4961 fi
4962 done
4963
4964 if test "x$cf_cv_make_PHONY" = xyes ; then
4965         cat >> Makefile <<-CF_EOF
4966
4967         .PHONY :        install.data
4968         .PHONY :        uninstall.data
4969 CF_EOF
4970 fi
4971
4972 if test "x$cf_with_db_install" = xyes; then
4973 cat >> Makefile <<CF_EOF
4974
4975 install.libs uninstall.libs \\
4976 install.data uninstall.data ::
4977 $MAKE_TERMINFO  ( cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4978 CF_EOF
4979 else
4980 cat >> Makefile <<CF_EOF
4981
4982 install.libs uninstall.libs ::
4983         ( cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4984 CF_EOF
4985 fi
4986
4987 if test "x$cf_with_manpages" = xyes; then
4988
4989 if test "x$cf_cv_make_PHONY" = xyes ; then
4990         cat >> Makefile <<-CF_EOF
4991
4992         .PHONY :        install.man
4993         .PHONY :        uninstall.man
4994 CF_EOF
4995 fi
4996
4997 cat >> Makefile <<CF_EOF
4998
4999 install.man \\
5000 uninstall.man ::
5001         ( cd man && \${MAKE} \${TOP_MFLAGS} \[$]@ )
5002 CF_EOF
5003 fi
5004
5005 cat >> Makefile <<CF_EOF
5006
5007 distclean ::
5008         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
5009         rm -f headers.sh headers.sed mk_shared_lib.sh
5010         rm -f edit_man.* man_alias.*
5011         rm -rf \${DIRS_TO_MAKE}
5012 CF_EOF
5013
5014 # Special case: tack's manpage lives in its own directory.
5015 if test "x$cf_with_manpages" = xyes; then
5016 if test "x$cf_with_tack" = "xyes"; then
5017 cat >> Makefile <<CF_EOF
5018
5019 install.man \\
5020 uninstall.man ::
5021         ( cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@ )
5022 CF_EOF
5023 fi
5024 fi
5025
5026 dnl If we're installing into a subdirectory of /usr/include, etc., we should
5027 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
5028 dnl anything, and will make it more standardized.  It's awkward to decide this
5029 dnl at configuration because of quoting, so we'll simply make all headers
5030 dnl installed via a script that can do the right thing.
5031
5032 rm -f headers.sed headers.sh
5033
5034 dnl ( generating this script makes the makefiles a little tidier :-)
5035 echo creating headers.sh
5036 cat >headers.sh <<CF_EOF
5037 #! $SHELL
5038 # This shell script is generated by the 'configure' script.  It is invoked in a
5039 # subdirectory of the build tree.  It generates a sed-script in the parent
5040 # directory that is used to adjust includes for header files that reside in a
5041 # subdirectory of /usr/include, etc.
5042 PRG=""
5043 while test \[$]# != 3
5044 do
5045 PRG="\$PRG \[$]1"; shift
5046 done
5047 DST=\[$]1
5048 REF=\[$]2
5049 SRC=\[$]3
5050 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
5051 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
5052 echo installing \$SRC in \$DST
5053 CF_EOF
5054
5055 if test "$WITH_CURSES_H" = yes; then
5056         cat >>headers.sh <<CF_EOF
5057 case \$DST in
5058 (/*/include/*)
5059         END=\`basename \$DST\`
5060         for i in \`cat \$REF/../*/headers |${FGREP-fgrep} -v "#"\`
5061         do
5062                 NAME=\`basename \$i\`
5063                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
5064         done
5065         ;;
5066 (*)
5067         echo "" >> \$TMPSED
5068         ;;
5069 esac
5070 CF_EOF
5071
5072 else
5073         cat >>headers.sh <<CF_EOF
5074 case \$DST in
5075 (/*/include/*)
5076         END=\`basename \$DST\`
5077         for i in \`cat \$REF/../*/headers |${FGREP-fgrep} -v "#"\`
5078         do
5079                 NAME=\`basename \$i\`
5080                 if test "\$NAME" = "curses.h"
5081                 then
5082                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
5083                         NAME=ncurses.h
5084                 fi
5085                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
5086         done
5087         ;;
5088 (*)
5089         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
5090         ;;
5091 esac
5092 CF_EOF
5093 fi
5094 cat >>headers.sh <<CF_EOF
5095 rm -f \$TMPSRC
5096 sed -f \$TMPSED \$SRC > \$TMPSRC
5097 NAME=\`basename \$SRC\`
5098 CF_EOF
5099 if test "$WITH_CURSES_H" != yes; then
5100         cat >>headers.sh <<CF_EOF
5101 test "\$NAME" = "curses.h" && NAME=ncurses.h
5102 CF_EOF
5103 fi
5104 cat >>headers.sh <<CF_EOF
5105 # Just in case someone gzip'd manpages, remove the conflicting copy.
5106 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
5107
5108 eval \$PRG \$TMPSRC \$DST/\$NAME
5109 rm -f \$TMPSRC \$TMPSED
5110 CF_EOF
5111
5112 chmod 0755 headers.sh
5113
5114 for cf_dir in $SRC_SUBDIRS
5115 do
5116         if test ! -d "$srcdir/$cf_dir" ; then
5117                 continue
5118         fi
5119
5120         if test -f "$srcdir/$cf_dir/headers" ; then
5121                 $AWK -f "$srcdir/mk-hdr.awk" \
5122                         subset="$LIB_SUBSETS" \
5123                         compat="$WITH_CURSES_H" \
5124                         "$srcdir/$cf_dir/headers" >>$cf_dir/Makefile
5125         fi
5126
5127         if test -f "$srcdir/$cf_dir/modules" ; then
5128                 if test "$cf_dir" != "c++" ; then
5129                         if test "x$cf_cv_make_PHONY" = xyes ; then
5130                                 cat >> $cf_dir/Makefile <<-CF_EOF
5131
5132                                 .PHONY :        depend
5133 CF_EOF
5134                         fi
5135
5136                         cat >>$cf_dir/Makefile <<"CF_EOF"
5137 depend : ${AUTO_SRC}
5138         makedepend -- ${CPPFLAGS} -- ${C_SRC}
5139
5140 # DO NOT DELETE THIS LINE -- make depend depends on it.
5141 CF_EOF
5142                 fi
5143         fi
5144 done
5145 AC_SUBST(Libs_To_Make)
5146 ])dnl
5147 dnl ---------------------------------------------------------------------------
5148 dnl CF_LIB_SONAME version: 9 updated: 2021/01/04 18:48:01
5149 dnl -------------
5150 dnl Find the and soname for the given shared library.  Set the cache variable
5151 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
5152 dnl variable to "unknown".
5153 dnl
5154 dnl $1 = headers
5155 dnl $2 = code
5156 dnl $3 = library name
5157 AC_DEFUN([CF_LIB_SONAME],
5158 [AC_REQUIRE([AC_PROG_FGREP])dnl
5159
5160 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
5161
5162 cf_cv_$3_soname=unknown
5163 if test "$cross_compiling" != yes ; then
5164 cat >conftest.$ac_ext <<CF_EOF
5165 $1
5166 int main(void)
5167 {
5168 $2
5169         ${cf_cv_main_return:-return}(0);
5170 }
5171 CF_EOF
5172 cf_save_LIBS="$LIBS"
5173         CF_ADD_LIB($3)
5174         if AC_TRY_EVAL(ac_compile) ; then
5175                 if AC_TRY_EVAL(ac_link) ; then
5176                         cf_cv_$3_soname="`ldd \"conftest$ac_exeext\" 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | ${FGREP-fgrep} lib$3.`"
5177                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
5178                 fi
5179         fi
5180 rm -rf ./conftest*
5181 LIBS="$cf_save_LIBS"
5182 fi
5183 ])
5184 ])
5185 dnl ---------------------------------------------------------------------------
5186 dnl CF_LIB_SUFFIX version: 28 updated: 2021/01/01 16:53:59
5187 dnl -------------
5188 dnl Compute the library file-suffix from the given model name
5189 dnl $1 = model name
5190 dnl $2 = variable to set (the nominal library suffix)
5191 dnl $3 = dependency variable to set (actual filename)
5192 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
5193 AC_DEFUN([CF_LIB_SUFFIX],
5194 [
5195         case X$1 in
5196         (Xlibtool)
5197                 $2='.la'
5198                 $3=[$]$2
5199                 ;;
5200         (Xdebug)
5201                 case "$cf_cv_system_name" in
5202                 (*-msvc*)
5203                         $2='_g.lib'
5204                         ;;
5205                 (*)
5206                         $2='_g.a'
5207                         ;;
5208                 esac
5209                 $3=[$]$2
5210                 ;;
5211         (Xprofile)
5212                 case "$cf_cv_system_name" in
5213                 (*-msvc*)
5214                         $2='_p.lib'
5215                         ;;
5216                 (*)
5217                         $2='_p.a'
5218                         ;;
5219                 esac
5220                 $3=[$]$2
5221                 ;;
5222         (Xshared)
5223                 case "$cf_cv_system_name" in
5224                 (aix[[5-7]]*)
5225                         $2='.so'
5226                         $3=[$]$2
5227                         ;;
5228                 (*-msvc*)
5229                         $2='.dll'
5230                         $3='.dll.lib'
5231                         ;;
5232                 (cygwin*|msys*|mingw*)
5233                         $2='.dll'
5234                         $3='.dll.a'
5235                         ;;
5236                 (darwin*)
5237                         $2='.dylib'
5238                         $3=[$]$2
5239                         ;;
5240                 (hpux*)
5241                         case "$target" in
5242                         (ia64*)
5243                                 $2='.so'
5244                                 $3=[$]$2
5245                                 ;;
5246                         (*)
5247                                 $2='.sl'
5248                                 $3=[$]$2
5249                                 ;;
5250                         esac
5251                         ;;
5252                 (*)
5253                         $2='.so'
5254                         $3=[$]$2
5255                         ;;
5256                 esac
5257                 ;;
5258         (*)
5259                 case "$target" in
5260                 (*-msvc*)
5261                         $2='.lib'
5262                         ;;
5263                 (*)
5264                         $2='.a'
5265                         ;;
5266                 esac
5267                 $3=[$]$2
5268                 ;;
5269         esac
5270         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
5271         then
5272                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
5273                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
5274         fi
5275 ])dnl
5276 dnl ---------------------------------------------------------------------------
5277 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
5278 dnl -----------
5279 dnl Compute the string to append to -library from the given model name
5280 dnl $1 = model name
5281 dnl $2 = variable to set
5282 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
5283 AC_DEFUN([CF_LIB_TYPE],
5284 [
5285         case $1 in
5286         (libtool) $2=''   ;;
5287         (normal)  $2=''   ;;
5288         (debug)   $2='_g' ;;
5289         (profile) $2='_p' ;;
5290         (shared)  $2=''   ;;
5291         esac
5292         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
5293 ])dnl
5294 dnl ---------------------------------------------------------------------------
5295 dnl CF_LINK_DATAONLY version: 13 updated: 2020/02/08 15:59:30
5296 dnl ----------------
5297 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
5298 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
5299 dnl have to provide wrappers for global tables to ensure they're linked
5300 dnl properly.
5301 AC_DEFUN([CF_LINK_DATAONLY],
5302 [
5303 AC_MSG_CHECKING([if data-only library module links])
5304 AC_CACHE_VAL(cf_cv_link_dataonly,[
5305         rm -f conftest.a
5306         cat >conftest.$ac_ext <<EOF
5307 #line __oline__ "configure"
5308 int     testdata[[3]] = { 123, 456, 789 };
5309 EOF
5310         if AC_TRY_EVAL(ac_compile) ; then
5311                 mv conftest.o data.o && \
5312                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
5313         fi
5314         rm -f conftest.$ac_ext data.o
5315         cat >conftest.$ac_ext <<EOF
5316 #line __oline__ "configure"
5317 int     testfunc(void)
5318 {
5319 #if defined(NeXT)
5320         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
5321 #else
5322         extern int testdata[[3]];
5323         return testdata[[0]] == 123
5324            &&  testdata[[1]] == 456
5325            &&  testdata[[2]] == 789;
5326 #endif
5327 }
5328 EOF
5329         if AC_TRY_EVAL(ac_compile); then
5330                 mv conftest.o func.o && \
5331                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
5332         fi
5333         rm -f conftest.$ac_ext func.o
5334         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
5335         cf_saveLIBS="$LIBS"
5336         LIBS="conftest.a $LIBS"
5337         AC_TRY_RUN([
5338         int main(void)
5339         {
5340                 extern int testfunc();
5341                 ${cf_cv_main_return:-return} (!testfunc());
5342         }
5343         ],
5344         [cf_cv_link_dataonly=yes],
5345         [cf_cv_link_dataonly=no],
5346         [cf_cv_link_dataonly=unknown])
5347         LIBS="$cf_saveLIBS"
5348         ])
5349 AC_MSG_RESULT($cf_cv_link_dataonly)
5350
5351 if test "$cf_cv_link_dataonly" = no ; then
5352         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
5353         BROKEN_LINKER=1
5354 fi
5355 AC_SUBST(BROKEN_LINKER)
5356
5357 ])dnl
5358 dnl ---------------------------------------------------------------------------
5359 dnl CF_LINK_FUNCS version: 12 updated: 2023/01/05 17:51:41
5360 dnl -------------
5361 dnl Most Unix systems have both link and symlink, a few don't have symlink.
5362 dnl A few non-Unix systems implement symlink, but not link.
5363 dnl A few non-systems implement neither (or have nonfunctional versions).
5364 dnl
5365 dnl This allows for a 2-second difference in modification times to allow for
5366 dnl some marginal NFS implementations.
5367 AC_DEFUN([CF_LINK_FUNCS],
5368 [
5369 AC_CHECK_HEADERS( \
5370 unistd.h \
5371 )
5372 AC_CHECK_FUNCS( \
5373         remove \
5374         unlink )
5375
5376 if test "$cross_compiling" = yes ; then
5377         AC_CHECK_FUNCS( \
5378                 link \
5379                 symlink )
5380 else
5381         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
5382                 cf_cv_link_funcs=
5383                 for cf_func in link symlink ; do
5384                         AC_TRY_RUN([
5385 $ac_includes_default
5386
5387 int main(void)
5388 {
5389         int fail = 0;
5390         char *src = "conftest.tmp";
5391         char *dst = "conftest.chk";
5392         struct stat src_sb, dst_sb;
5393         FILE *fp = fopen(src, "w");
5394         if (fp == 0) { fail = 3; } else {
5395                 fclose(fp); stat(src, &src_sb);
5396                 if ($cf_func(src, dst) < 0) {
5397                         fail = 1;
5398                 } else if (stat(dst, &dst_sb) < 0) {
5399                         fail = 2;
5400                 } else {
5401                         long diff = (dst_sb.st_mtime - src_sb.st_mtime);
5402                         if (diff < 0) diff = -diff;
5403                         if (diff > 2) fail = 3;
5404                 }
5405         }
5406 #ifdef HAVE_UNLINK
5407         unlink(dst); unlink(src);
5408 #else
5409         remove(dst); remove(src);
5410 #endif
5411         ${cf_cv_main_return:-return} (fail);
5412 }
5413                         ],[
5414                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
5415                         eval 'ac_cv_func_'$cf_func'=yes'],[
5416                         eval 'ac_cv_func_'$cf_func'=no'],[
5417                         eval 'ac_cv_func_'$cf_func'=error'])
5418                 done
5419                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
5420         ])
5421         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
5422         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
5423 fi
5424 ])dnl
5425 dnl ---------------------------------------------------------------------------
5426 dnl CF_MAKEFLAGS version: 21 updated: 2021/09/04 06:47:34
5427 dnl ------------
5428 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
5429 dnl options to lower-levels.  It is very useful for "make -n" -- if we have it.
5430 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
5431 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
5432 AC_DEFUN([CF_MAKEFLAGS],
5433 [AC_REQUIRE([AC_PROG_FGREP])dnl
5434
5435 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
5436         cf_cv_makeflags=''
5437         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
5438         do
5439                 cat >cf_makeflags.tmp <<CF_EOF
5440 SHELL = $SHELL
5441 all :
5442         @ echo '.$cf_option'
5443 CF_EOF
5444                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | ${FGREP-fgrep} -v "ing directory" | sed -e 's,[[  ]]*$,,'`
5445                 case "$cf_result" in
5446                 (.*k|.*kw)
5447                         cf_result="`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`"
5448                         case "$cf_result" in
5449                         (.*CC=*)        cf_cv_makeflags=
5450                                 ;;
5451                         (*)     cf_cv_makeflags=$cf_option
5452                                 ;;
5453                         esac
5454                         break
5455                         ;;
5456                 (.-)
5457                         ;;
5458                 (*)
5459                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
5460                         ;;
5461                 esac
5462         done
5463         rm -f cf_makeflags.tmp
5464 ])
5465
5466 AC_SUBST(cf_cv_makeflags)
5467 ])dnl
5468 dnl ---------------------------------------------------------------------------
5469 dnl CF_MAKE_PHONY version: 3 updated: 2021/01/08 16:08:21
5470 dnl -------------
5471 dnl Check if the make-program handles a ".PHONY" target, e.g,. a target which
5472 dnl acts as a placeholder.
5473 dnl
5474 dnl The ".PHONY" feature was proposed in 2011 here
5475 dnl     https://www.austingroupbugs.net/view.php?id=523
5476 dnl and is scheduled for release in P1003.1 Issue 8 (late 2022).
5477 dnl
5478 dnl This is not supported by SVr4 make (or SunOS 4, 4.3SD, etc), but works with
5479 dnl a few others (i.e., GNU make and the non-POSIX "BSD" make):
5480 dnl
5481 dnl + This is a GNU make feature (since April 1988, but in turn from binutils,
5482 dnl   date unspecified).
5483 dnl
5484 dnl + It was adopted in NetBSD make in June 1995.
5485 dnl
5486 dnl + The other BSD make programs are derived from the NetBSD make (and for
5487 dnl   that reason are not actually different "implementations").
5488 dnl
5489 dnl + Some features of NetBSD make were actually adapted from pmake, which
5490 dnl   began as a modified GNU make starting in 1993.
5491 dnl
5492 dnl + Version 3.8 of the dmake program in January 1992 also implemented this
5493 dnl   GNU make extension, but is less well known than the BSD make.
5494 AC_DEFUN([CF_MAKE_PHONY],[
5495 AC_CACHE_CHECK(for \".PHONY\" make-support, cf_cv_make_PHONY,[
5496         rm -rf conftest*
5497         (
5498                 mkdir conftest || exit 1
5499                 cd conftest
5500                 cat >makefile <<'CF_EOF'
5501 .PHONY: always
5502 DATA=0
5503 always: always.out
5504         @echo "** making [$]@ [$](DATA)"
5505 once: once.out
5506         @echo "** making [$]@ [$](DATA)"
5507 always.out:
5508         @echo "** making [$]@ [$](DATA)"
5509         echo [$](DATA) > [$]@
5510 once.out:
5511         @echo "** making [$]@ [$](DATA)"
5512         echo [$](DATA) > [$]@
5513 CF_EOF
5514                 for cf_data in 1 2 3
5515                 do
5516                         ${MAKE:-make} always DATA=$cf_data
5517                         ${MAKE:-make} once   DATA=$cf_data
5518                         ${MAKE:-make} -t always once
5519                         if test -f always ; then
5520                                 echo "no (case 1)" > ../conftest.tmp
5521                         elif test ! -f always.out ; then
5522                                 echo "no (case 2)" > ../conftest.tmp
5523                         elif test ! -f once.out ; then
5524                                 echo "no (case 3)" > ../conftest.tmp
5525                         elif ! cmp -s always.out once.out ; then
5526                                 echo "no (case 4)" > ../conftest.tmp
5527                                 diff always.out once.out
5528                         else
5529                                 cf_check="`cat always.out`"
5530                                 if test "x$cf_check" != "x$cf_data" ; then
5531                                         echo "no (case 5)" > ../conftest.tmp
5532                                 else
5533                                         echo yes > ../conftest.tmp
5534                                         rm -f ./*.out
5535                                         continue
5536                                 fi
5537                         fi
5538                         break
5539                 done
5540         ) >&AC_FD_CC 2>&1
5541         cf_cv_make_PHONY="`cat conftest.tmp`"
5542         rm -rf conftest*
5543 ])
5544 MAKE_NO_PHONY="#"
5545 MAKE_PHONY="#"
5546 test "x$cf_cv_make_PHONY" = xyes && MAKE_PHONY=
5547 test "x$cf_cv_make_PHONY" != xyes && MAKE_NO_PHONY=
5548 AC_SUBST(MAKE_NO_PHONY)
5549 AC_SUBST(MAKE_PHONY)
5550 ])dnl
5551 dnl ---------------------------------------------------------------------------
5552 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
5553 dnl ------------
5554 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
5555 dnl a monocase filesystem.
5556 AC_DEFUN([CF_MAKE_TAGS],[
5557 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
5558
5559 AC_CHECK_PROGS(CTAGS, exctags ctags)
5560 AC_CHECK_PROGS(ETAGS, exetags etags)
5561
5562 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
5563
5564 if test "$cf_cv_mixedcase" = yes ; then
5565         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
5566 else
5567         MAKE_UPPER_TAGS=no
5568 fi
5569
5570 if test "$MAKE_UPPER_TAGS" = yes ; then
5571         MAKE_UPPER_TAGS=
5572 else
5573         MAKE_UPPER_TAGS="#"
5574 fi
5575
5576 if test "$MAKE_LOWER_TAGS" = yes ; then
5577         MAKE_LOWER_TAGS=
5578 else
5579         MAKE_LOWER_TAGS="#"
5580 fi
5581
5582 AC_SUBST(CTAGS)
5583 AC_SUBST(ETAGS)
5584
5585 AC_SUBST(MAKE_UPPER_TAGS)
5586 AC_SUBST(MAKE_LOWER_TAGS)
5587 ])dnl
5588 dnl ---------------------------------------------------------------------------
5589 dnl CF_MANPAGE_FORMAT version: 16 updated: 2022/11/05 16:12:11
5590 dnl -----------------
5591 dnl Option to allow user to override automatic configuration of manpage format.
5592 dnl There are several special cases:
5593 dnl
5594 dnl     compress - man checks for, can display compressed files
5595 dnl     bzip2 - man checks for, can display bzip2'd files
5596 dnl     gzip - man checks for, can display gzip'd files
5597 dnl     xz - man checks for, can display xz'd files
5598 dnl
5599 dnl     BSDI - files in the cat-directories are suffixed ".0"
5600 dnl     formatted - installer should format (put files in cat-directory)
5601 dnl     catonly - installer should only format, e.g., for a turnkey system.
5602 dnl
5603 dnl There are other configurations which this macro does not test, e.g., HPUX's
5604 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
5605 dnl convention would not match our use).
5606 AC_DEFUN([CF_MANPAGE_FORMAT],
5607 [
5608 AC_REQUIRE([CF_PATHSEP])
5609 AC_MSG_CHECKING(format of man-pages)
5610
5611 AC_ARG_WITH(manpage-format,
5612         [  --with-manpage-format   specify manpage-format: gzip/compress/bzip2/xz,
5613                           BSDI/normal and optionally formatted/catonly,
5614                           e.g., gzip,formatted],
5615         [MANPAGE_FORMAT=$withval],
5616         [MANPAGE_FORMAT=unknown])
5617
5618 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
5619 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
5620
5621 cf_unknown=
5622
5623 case "$MANPAGE_FORMAT" in
5624 (unknown)
5625         if test -z "$MANPATH" ; then
5626                 MANPATH="/usr/man:/usr/share/man"
5627         fi
5628
5629         # look for the 'date' man-page (it is most likely to be installed!)
5630         MANPAGE_FORMAT=
5631         cf_preform="no"
5632         cf_catonly="yes"
5633         cf_example="date"
5634
5635         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
5636         for cf_dir in $MANPATH; do
5637                 test -z "$cf_dir" && cf_dir=/usr/man
5638                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
5639                 do
5640                         cf_test=`echo "$cf_name" | sed -e 's/*//'`
5641                         if test "x$cf_test" = "x$cf_name" ; then
5642
5643                                 case "$cf_name" in
5644                                 (*.bz2) MANPAGE_FORMAT="$MANPAGE_FORMAT bzip2";;
5645                                 (*.xz)  MANPAGE_FORMAT="$MANPAGE_FORMAT xz";;
5646                                 (*.gz)  MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
5647                                 (*.Z)   MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
5648                                 (*.0)   MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
5649                                 (*)     MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
5650                                 esac
5651
5652                                 case "$cf_name" in
5653                                 ($cf_dir/man*)
5654                                         cf_catonly=no
5655                                         ;;
5656                                 ($cf_dir/cat*)
5657                                         cf_preform=yes
5658                                         ;;
5659                                 esac
5660                                 break
5661                         fi
5662
5663                         # if we found a match in either man* or cat*, stop looking
5664                         if test -n "$MANPAGE_FORMAT" ; then
5665                                 cf_found=no
5666                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
5667                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
5668                                 case "$cf_name" in
5669                                 ($cf_dir/cat*)
5670                                         cf_found=yes
5671                                         ;;
5672                                 esac
5673                                 test "$cf_found" = yes && break
5674                         fi
5675                 done
5676                 # only check the first directory in $MANPATH where we find manpages
5677                 if test -n "$MANPAGE_FORMAT" ; then
5678                         break
5679                 fi
5680         done
5681         # if we did not find the example, just assume it is normal
5682         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
5683         IFS="$ac_save_ifs"
5684         ;;
5685 (*)
5686         for cf_option in $MANPAGE_FORMAT; do
5687         case "$cf_option" in
5688         (xz|bzip2|gzip|compress|BSDI|normal|formatted|catonly)
5689                 ;;
5690         (*)
5691                 cf_unknown="$cf_unknown $cf_option"
5692                 ;;
5693         esac
5694         done
5695         ;;
5696 esac
5697
5698 AC_MSG_RESULT($MANPAGE_FORMAT)
5699 if test -n "$cf_unknown" ; then
5700         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
5701 fi
5702 ])dnl
5703 dnl ---------------------------------------------------------------------------
5704 dnl CF_MANPAGE_RENAMES version: 17 updated: 2022/10/23 07:46:29
5705 dnl ------------------
5706 dnl The Debian people have their own naming convention for manpages.  This
5707 dnl option lets us override the name of the file containing renaming, or
5708 dnl disable it altogether.
5709 AC_DEFUN([CF_MANPAGE_RENAMES],
5710 [
5711 AC_MSG_CHECKING(for manpage renaming)
5712
5713 AC_ARG_WITH(manpage-renames,
5714         [  --with-manpage-renames  specify manpage-renaming],
5715         [MANPAGE_RENAMES=$withval],
5716         [MANPAGE_RENAMES=yes])
5717
5718 case ".$MANPAGE_RENAMES" in
5719 (.no)
5720         ;;
5721 (.|.yes)
5722         # Debian 'man' program?
5723         if test -f /etc/debian_version ; then
5724                 MANPAGE_RENAMES=man/man_db.renames
5725         else
5726                 MANPAGE_RENAMES=no
5727         fi
5728         ;;
5729 esac
5730
5731 if test "$MANPAGE_RENAMES" = man/man_db.renames ; then
5732         MANPAGE_RENAMES=`pwd`/$MANPAGE_RENAMES
5733 elif test "$MANPAGE_RENAMES" = no ; then
5734         :
5735 elif test ! -f "$MANPAGE_RENAMES" ; then
5736         AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
5737 fi
5738
5739 AC_MSG_RESULT($MANPAGE_RENAMES)
5740 AC_SUBST(MANPAGE_RENAMES)
5741 ])dnl
5742 dnl ---------------------------------------------------------------------------
5743 dnl CF_MANPAGE_SYMLINKS version: 6 updated: 2015/04/17 21:13:04
5744 dnl -------------------
5745 dnl Some people expect each tool to make all aliases for manpages in the
5746 dnl man-directory.  This accommodates the older, less-capable implementations
5747 dnl of 'man', and is optional.
5748 AC_DEFUN([CF_MANPAGE_SYMLINKS],
5749 [
5750 AC_MSG_CHECKING(if manpage aliases will be installed)
5751
5752 AC_ARG_WITH(manpage-aliases,
5753         [  --with-manpage-aliases  specify manpage-aliases using .so],
5754         [MANPAGE_ALIASES=$withval],
5755         [MANPAGE_ALIASES=yes])
5756
5757 AC_MSG_RESULT($MANPAGE_ALIASES)
5758
5759 case "x$LN_S" in
5760 (xln*)
5761         cf_use_symlinks=yes
5762         ;;
5763 (*)
5764         cf_use_symlinks=no
5765         ;;
5766 esac
5767
5768 MANPAGE_SYMLINKS=no
5769 if test "$MANPAGE_ALIASES" = yes ; then
5770 AC_MSG_CHECKING(if manpage symlinks should be used)
5771
5772 AC_ARG_WITH(manpage-symlinks,
5773         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
5774         [MANPAGE_SYMLINKS=$withval],
5775         [MANPAGE_SYMLINKS=$cf_use_symlinks])
5776
5777 if test "$$cf_use_symlinks" = no; then
5778 if test "$MANPAGE_SYMLINKS" = yes ; then
5779         AC_MSG_WARN(cannot make symlinks, will use .so files)
5780         MANPAGE_SYMLINKS=no
5781 fi
5782 fi
5783
5784 AC_MSG_RESULT($MANPAGE_SYMLINKS)
5785 fi
5786
5787 ])dnl
5788 dnl ---------------------------------------------------------------------------
5789 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
5790 dnl --------------
5791 dnl This option causes manpages to be run through tbl(1) to generate tables
5792 dnl correctly.
5793 AC_DEFUN([CF_MANPAGE_TBL],
5794 [
5795 AC_MSG_CHECKING(for manpage tbl)
5796
5797 AC_ARG_WITH(manpage-tbl,
5798         [  --with-manpage-tbl      specify manpage processing with tbl],
5799         [MANPAGE_TBL=$withval],
5800         [MANPAGE_TBL=no])
5801
5802 AC_MSG_RESULT($MANPAGE_TBL)
5803 ])dnl
5804 dnl ---------------------------------------------------------------------------
5805 dnl CF_MAN_PAGES version: 54 updated: 2022/11/05 16:12:11
5806 dnl ------------
5807 dnl Try to determine if the man-pages on the system are compressed, and if
5808 dnl so, what format is used.  Use this information to construct a script that
5809 dnl will install man-pages.
5810 AC_DEFUN([CF_MAN_PAGES],
5811 [
5812 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
5813 CF_MANPAGE_FORMAT
5814 CF_MANPAGE_RENAMES
5815 CF_MANPAGE_SYMLINKS
5816 CF_MANPAGE_TBL
5817
5818 if test "$prefix" = "NONE" ; then
5819         cf_prefix="$ac_default_prefix"
5820 else
5821         cf_prefix="$prefix"
5822 fi
5823
5824 case "$MANPAGE_FORMAT" in
5825 (*catonly*)
5826         cf_format=yes
5827         cf_inboth=no
5828         ;;
5829 (*formatted*)
5830         cf_format=yes
5831         cf_inboth=yes
5832         ;;
5833 (*)
5834         cf_format=no
5835         cf_inboth=no
5836         ;;
5837 esac
5838
5839 test ! -d man && mkdir man
5840
5841 cf_so_strip=
5842 cf_compress=
5843 for cf_manpage_format in $MANPAGE_FORMAT
5844 do
5845 case "$cf_manpage_format" in
5846 (compress)
5847         cf_so_strip="Z"
5848         cf_compress=compress
5849         ;;
5850 (gzip)
5851         cf_so_strip="gz"
5852         cf_compress=gzip
5853         ;;
5854 (bzip2)
5855         cf_so_strip="bz2"
5856         cf_compress=bzip2
5857         ;;
5858 (xz)
5859         cf_so_strip="xz"
5860         cf_compress=xz
5861         ;;
5862 esac
5863 done
5864
5865 cf_edit_man=./edit_man.sh
5866 cf_man_alias=`pwd`/man_alias.sed
5867
5868 cat >$cf_edit_man <<CF_EOF
5869 #! $SHELL
5870 # this script is generated by the configure-script CF_MAN_PAGES macro.
5871
5872 prefix="$cf_prefix"
5873 datarootdir="$datarootdir"
5874 datadir="$datadir"
5875
5876 NCURSES_MAJOR="$NCURSES_MAJOR"
5877 NCURSES_MINOR="$NCURSES_MINOR"
5878 NCURSES_PATCH="$NCURSES_PATCH"
5879
5880 NCURSES_OSPEED="$NCURSES_OSPEED"
5881 TERMINFO="$TERMINFO"
5882
5883 INSTALL="$INSTALL"
5884 INSTALL_DATA="$INSTALL_DATA"
5885
5886 transform="$program_transform_name"
5887
5888 TMP=\${TMPDIR:=/tmp}/man\$\$
5889 trap "rm -f \$TMP; exit 1" 1 2 3 15
5890 trap "rm -f \$TMP" 0
5891
5892 form=\[$]1
5893 shift || exit 1
5894
5895 verb=\[$]1
5896 shift || exit 1
5897
5898 mandir=\[$]1
5899 shift || exit 1
5900
5901 srcdir=\[$]1
5902 top_srcdir=\[$]srcdir/..
5903 shift || exit 1
5904
5905 if test "\$form" = normal ; then
5906         if test "$cf_format" = yes ; then
5907         if test "$cf_inboth" = no ; then
5908                 $SHELL "\[$]0" format "\$verb" "\$mandir" "\$srcdir" "\[$]@"
5909                 exit $?
5910         fi
5911         fi
5912         cf_subdir=\$mandir/man
5913         cf_tables=$MANPAGE_TBL
5914 else
5915         cf_subdir=\$mandir/cat
5916         cf_tables=yes
5917 fi
5918
5919 # process the list of source-files
5920 for i in "\[$]@" ; do
5921 case \$i in
5922 (*.orig|*.rej) ;;
5923 (*.[[0-9]]*)
5924         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
5925         if test "\$verb" = installing ; then
5926         if test ! -d "\$cf_subdir\${section}" ; then
5927                 mkdir -p "\$cf_subdir\$section"
5928         fi
5929         fi
5930
5931         # replace variables in man page
5932         if test ! -f "$cf_man_alias" ; then
5933 cat >>$cf_man_alias <<-CF_EOF2
5934                 s,@DATADIR@,\$datadir,g
5935                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
5936                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
5937                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
5938                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
5939                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
5940                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
5941 CF_EOF
5942         ifelse($1,,,[
5943         for cf_name in $1
5944         do
5945                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
5946                 cf_name=`echo "$cf_name" | sed "$program_transform_name"`
5947 cat >>$cf_edit_man <<-CF_EOF
5948                 s,@$cf_NAME@,$cf_name,g
5949 CF_EOF
5950         done
5951         ])
5952 cat >>$cf_edit_man <<CF_EOF
5953 CF_EOF2
5954                 echo "...made $cf_man_alias"
5955         fi
5956
5957         aliases=
5958         cf_source=\`basename "\$i"\`
5959         inalias=\$cf_source
5960         test ! -f "\$inalias" && inalias="\$srcdir/\$inalias"
5961         if test ! -f "\$inalias" ; then
5962                 echo ".. skipped \$cf_source"
5963                 continue
5964         fi
5965 CF_EOF
5966
5967 if test "$MANPAGE_ALIASES" != no ; then
5968 cat >>$cf_edit_man <<CF_EOF
5969         nCurses=ignore.3x
5970         test "$with_curses_h" = yes && nCurses=ncurses.3x
5971         aliases=\`sed -f "\$top_srcdir/man/manlinks.sed" "\$inalias" |sed -f "$cf_man_alias" | sort -u; test "\$inalias" = "\$nCurses" && echo curses\`
5972 CF_EOF
5973 fi
5974
5975 if test "$MANPAGE_RENAMES" = no ; then
5976 cat >>$cf_edit_man <<CF_EOF
5977         # perform program transformations for section 1 man pages
5978         if test \$section = 1 ; then
5979                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
5980         else
5981                 cf_target=\$cf_subdir\${section}/\$cf_source
5982         fi
5983 CF_EOF
5984 else
5985 cat >>$cf_edit_man <<CF_EOF
5986         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
5987         if test -z "\$cf_target" ; then
5988                 echo "? missing rename for \$cf_source"
5989                 cf_target="\$cf_source"
5990         fi
5991         cf_target="\$cf_subdir\${section}/\${cf_target}"
5992
5993 CF_EOF
5994 fi
5995
5996 cat >>$cf_edit_man <<CF_EOF
5997         sed     -f "$cf_man_alias" \\
5998 CF_EOF
5999
6000 if test "$MANPAGE_RENAMES" != no ; then
6001 cat >>$cf_edit_man <<CF_EOF
6002                 < "\$i" | sed -f `pwd`/edit_man.sed >\$TMP
6003 CF_EOF
6004 else
6005 cat >>$cf_edit_man <<CF_EOF
6006                 < "\$i" >\$TMP
6007 CF_EOF
6008 fi
6009
6010 cat >>$cf_edit_man <<CF_EOF
6011 if test \$cf_tables = yes ; then
6012         tbl \$TMP >\$TMP.out
6013         mv \$TMP.out \$TMP
6014 fi
6015 CF_EOF
6016
6017 if test "$with_overwrite" != yes ; then
6018 cat >>$cf_edit_man <<CF_EOF
6019         sed -e "/\\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
6020         mv \$TMP.out \$TMP
6021 CF_EOF
6022 fi
6023
6024 if test "$with_curses_h" != yes ; then
6025 cat >>$cf_edit_man <<CF_EOF
6026         sed -e "/\\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
6027         mv \$TMP.out \$TMP
6028 CF_EOF
6029 fi
6030
6031 cat >>$cf_edit_man <<CF_EOF
6032         if test "\$form" = format ; then
6033                 nroff -man \$TMP >\$TMP.out
6034                 mv \$TMP.out \$TMP
6035         fi
6036 CF_EOF
6037
6038 if test -n "$cf_compress" ; then
6039 cat >>$cf_edit_man <<CF_EOF
6040         if test "\$verb" = installing ; then
6041         if ( "$cf_compress" -f \$TMP )
6042         then
6043                 mv \$TMP.$cf_so_strip \$TMP
6044         fi
6045         fi
6046         cf_target="\$cf_target.$cf_so_strip"
6047 CF_EOF
6048 fi
6049
6050 case "$MANPAGE_FORMAT" in
6051 (*BSDI*)
6052 cat >>$cf_edit_man <<CF_EOF
6053         if test "\$form" = format ; then
6054                 # BSDI installs only .0 suffixes in the cat directories
6055                 cf_target="\`echo \$cf_target|sed -e 's/\\.[[1-9]]\\+[[a-z]]*/.0/'\`"
6056         fi
6057 CF_EOF
6058   ;;
6059 esac
6060
6061 cat >>$cf_edit_man <<CF_EOF
6062         suffix=\`basename "\$cf_target" | sed -e 's%^[[^.]]*%%'\`
6063         if test "\$verb" = installing ; then
6064                 echo "\$verb \$cf_target"
6065                 \$INSTALL_DATA \$TMP "\$cf_target"
6066                 test -d "\$cf_subdir\${section}" &&
6067                 test -n "\$aliases" && (
6068                         cd "\$cf_subdir\${section}" && (
6069                                 cf_source=\`echo "\$cf_target" |sed -e 's%^.*/\\([[^/]][[^/]]*/[[^/]][[^/]]*$\\)%\\1%'\`
6070                                 test -n "$cf_so_strip" && cf_source=\`echo "\$cf_source" |sed -e 's%\\.$cf_so_strip\$%%'\`
6071                                 cf_target=\`basename "\$cf_target"\`
6072                                 for cf_alias in \$aliases
6073                                 do
6074                                         if test "\$section" = 1 ; then
6075                                                 cf_alias=\`echo "\$cf_alias" |sed "\${transform}"\`
6076                                         fi
6077
6078                                         if test "$MANPAGE_SYMLINKS" = yes ; then
6079                                                 if test -f "\$cf_alias\${suffix}" ; then
6080                                                         if ( cmp -s "\$cf_target" "\$cf_alias\${suffix}" )
6081                                                         then
6082                                                                 continue
6083                                                         fi
6084                                                 fi
6085                                                 echo ".. \$verb alias \$cf_alias\${suffix}"
6086 CF_EOF
6087 case "x$LN_S" in
6088 (*-f)
6089 cat >>$cf_edit_man <<CF_EOF
6090                                                 $LN_S "\$cf_target" "\$cf_alias\${suffix}"
6091 CF_EOF
6092         ;;
6093 (*)
6094 cat >>$cf_edit_man <<CF_EOF
6095                                                 rm -f "\$cf_alias\${suffix}"
6096                                                 $LN_S "\$cf_target" "\$cf_alias\${suffix}"
6097 CF_EOF
6098         ;;
6099 esac
6100 cat >>$cf_edit_man <<CF_EOF
6101                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
6102                                                 echo ".so \$cf_source" >\$TMP
6103 CF_EOF
6104 if test -n "$cf_compress" ; then
6105 cat >>$cf_edit_man <<CF_EOF
6106                                                 if test -n "$cf_so_strip" ; then
6107                                                         "$cf_compress" -f \$TMP
6108                                                         mv \$TMP.$cf_so_strip \$TMP
6109                                                 fi
6110 CF_EOF
6111 fi
6112 cat >>$cf_edit_man <<CF_EOF
6113                                                 echo ".. \$verb alias \$cf_alias\${suffix}"
6114                                                 rm -f "\$cf_alias\${suffix}"
6115                                                 \$INSTALL_DATA \$TMP "\$cf_alias\${suffix}"
6116                                         fi
6117                                 done
6118                         )
6119                 )
6120         elif test "\$verb" = removing ; then
6121                 test -f "\$cf_target" && (
6122                         echo "\$verb \$cf_target"
6123                         rm -f "\$cf_target"
6124                 )
6125                 test -d "\$cf_subdir\${section}" &&
6126                 test -n "\$aliases" && (
6127                         cd "\$cf_subdir\${section}" && (
6128                                 for cf_alias in \$aliases
6129                                 do
6130                                         if test "\$section" = 1 ; then
6131                                                 cf_alias=\`echo "\$cf_alias" |sed "\${transform}"\`
6132                                         fi
6133
6134                                         echo ".. \$verb alias \$cf_alias\${suffix}"
6135                                         rm -f "\$cf_alias\${suffix}"
6136                                 done
6137                         )
6138                 )
6139         else
6140 #               echo ".hy 0"
6141                 cat \$TMP
6142         fi
6143         ;;
6144 esac
6145 done
6146
6147 if test "$cf_inboth" = yes ; then
6148 if test "\$form" != format ; then
6149         $SHELL "\[$]0" format "\$verb" "\$mandir" "\$srcdir" "\[$]@"
6150 fi
6151 fi
6152
6153 exit 0
6154 CF_EOF
6155 chmod 755 "$cf_edit_man"
6156
6157 ])dnl
6158 dnl ---------------------------------------------------------------------------
6159 dnl CF_MAP_LIB_BASENAME version: 2 updated: 2021/01/02 17:09:14
6160 dnl -------------------
6161 dnl Convert a default-libname to the actual one used via CF_WITH_LIB_BASENAME.
6162 dnl
6163 dnl $1 = variable to set
6164 dnl $2 = default-libname
6165 AC_DEFUN([CF_MAP_LIB_BASENAME],[
6166 CF_UPPER(cf_map_lib_basename,$2)
6167 eval $1="\$${cf_map_lib_basename}_NAME"
6168 ])dnl
6169 dnl ---------------------------------------------------------------------------
6170 dnl CF_MATH_LIB version: 11 updated: 2022/07/27 19:01:48
6171 dnl -----------
6172 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
6173 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
6174 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
6175 AC_DEFUN([CF_MATH_LIB],
6176 [
6177 AC_CACHE_CHECK(if -lm needed for math functions,
6178         cf_cv_need_libm,[
6179         AC_TRY_LINK([
6180                 #include <stdio.h>
6181                 #include <stdlib.h>
6182                 #include <math.h>
6183         ],
6184         [double x = rand(); printf("result = %g\\n", ]ifelse([$2],,sin(x),$2)[)],
6185         [cf_cv_need_libm=no],
6186         [cf_cv_need_libm=yes])])
6187
6188 if test "$cf_cv_need_libm" = yes
6189 then
6190
6191         cf_save_LIBS="$LIBS"
6192         LIBS="$LIBS -lm"
6193         AC_CACHE_CHECK(if -lm is available for math functions,
6194         cf_cv_have_libm,[
6195         AC_TRY_LINK([
6196                 #include <stdio.h>
6197                 #include <stdlib.h>
6198                 #include <math.h>
6199         ],
6200         [double x = rand(); printf("result = %g\\n", ]ifelse([$2],,sin(x),$2)[)],
6201         [cf_cv_have_libm=yes],
6202         [cf_cv_have_libm=no])])
6203         LIBS="$cf_save_LIBS"
6204
6205         if test "$cf_cv_have_libm" = yes
6206         then
6207                 ifelse($1,,[CF_ADD_LIB(m)],[$1=-lm])
6208         fi
6209 else
6210         cf_cv_have_libm=yes
6211 fi
6212
6213 if test "$cf_cv_have_libm" = yes
6214 then
6215         AC_DEFINE(HAVE_MATH_FUNCS,1,[Define to 1 if math functions are available])
6216 fi
6217 ])
6218 dnl ---------------------------------------------------------------------------
6219 dnl CF_MIXEDCASE_FILENAMES version: 9 updated: 2021/01/01 16:53:59
6220 dnl ----------------------
6221 dnl Check if the file-system supports mixed-case filenames.  If we're able to
6222 dnl create a lowercase name and see it as uppercase, it doesn't support that.
6223 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
6224 [
6225 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
6226 if test "$cross_compiling" = yes ; then
6227         case "$target_alias" in
6228         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*|darwin*)
6229                 cf_cv_mixedcase=no
6230                 ;;
6231         (*)
6232                 cf_cv_mixedcase=yes
6233                 ;;
6234         esac
6235 else
6236         rm -f conftest CONFTEST
6237         echo test >conftest
6238         if test -f CONFTEST ; then
6239                 cf_cv_mixedcase=no
6240         else
6241                 cf_cv_mixedcase=yes
6242         fi
6243         rm -f conftest CONFTEST
6244 fi
6245 ])
6246 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
6247 ])dnl
6248 dnl ---------------------------------------------------------------------------
6249 dnl CF_MKSTEMP version: 12 updated: 2023/01/05 17:53:11
6250 dnl ----------
6251 dnl Check for a working mkstemp.  This creates two files, checks that they are
6252 dnl successfully created and distinct (AmigaOS apparently fails on the last).
6253 AC_DEFUN([CF_MKSTEMP],[
6254 AC_CHECK_HEADERS( \
6255 unistd.h \
6256 )
6257 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
6258 rm -rf ./conftest*
6259 AC_TRY_RUN([
6260 $ac_includes_default
6261
6262 int main(void)
6263 {
6264         char *tmpl = "conftestXXXXXX";
6265         char name[2][80];
6266         int n;
6267         int result = 0;
6268         int fd;
6269         struct stat sb;
6270
6271         umask(077);
6272         for (n = 0; n < 2; ++n) {
6273                 strcpy(name[n], tmpl);
6274                 if ((fd = mkstemp(name[n])) >= 0) {
6275                         if (!strcmp(name[n], tmpl)
6276                          || stat(name[n], &sb) != 0
6277                          || (sb.st_mode & S_IFMT) != S_IFREG
6278                          || (sb.st_mode & 077) != 0) {
6279                                 result = 1;
6280                         }
6281                         close(fd);
6282                 }
6283         }
6284         if (result == 0
6285          && !strcmp(name[0], name[1]))
6286                 result = 1;
6287         ${cf_cv_main_return:-return}(result);
6288 }
6289 ],[cf_cv_func_mkstemp=yes
6290 ],[cf_cv_func_mkstemp=no
6291 ],[cf_cv_func_mkstemp=maybe])
6292 ])
6293 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
6294         AC_CHECK_FUNC(mkstemp)
6295 fi
6296 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
6297         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
6298 fi
6299 ])dnl
6300 dnl ---------------------------------------------------------------------------
6301 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
6302 dnl ----------
6303 dnl Write a debug message to config.log, along with the line number in the
6304 dnl configure script.
6305 AC_DEFUN([CF_MSG_LOG],[
6306 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
6307 ])dnl
6308 dnl ---------------------------------------------------------------------------
6309 dnl CF_NCURSES_ABI_6 version: 5 updated: 2023/01/07 16:32:06
6310 dnl ----------------
6311 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
6312 dnl warn about this.
6313 AC_DEFUN([CF_NCURSES_ABI_6],[
6314 if test "${with_abi_version+set}" != set; then
6315         case "$cf_cv_rel_version" in
6316         (5.*)
6317                 cf_cv_rel_version=6.0
6318                 cf_cv_abi_version=6
6319                 cf_cv_abi_default=6
6320                 AC_MSG_WARN(overriding ABI version to $cf_cv_abi_default)
6321                 ;;
6322         esac
6323 fi
6324 ])dnl
6325 dnl ---------------------------------------------------------------------------
6326 dnl CF_NCURSES_WITH_ABI_VERSION version: 3 updated: 2021/01/01 13:31:04
6327 dnl ---------------------------
6328 dnl Allow ncurses's ABI to be overridden.  Generally this happens when a
6329 dnl packager has incremented the ABI past that used in the original package,
6330 dnl and wishes to keep doing this.
6331 dnl
6332 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
6333 dnl symbol.
6334 AC_DEFUN([CF_NCURSES_WITH_ABI_VERSION],[
6335 CF_WITH_ABI_VERSION($1)
6336 if test "x$cf_cv_abi_version" != "x$with_abi_version"
6337 then
6338         case "$cf_cv_rel_version" in
6339         (5.*)
6340                 cf_cv_rel_version=$with_abi_version.0
6341                 ;;
6342         esac
6343 fi
6344 ])dnl
6345 dnl ---------------------------------------------------------------------------
6346 dnl CF_NO_LEAKS_OPTION version: 9 updated: 2021/06/13 19:45:41
6347 dnl ------------------
6348 dnl see CF_WITH_NO_LEAKS
6349 dnl
6350 dnl $1 = option/name
6351 dnl $2 = help-text
6352 dnl $3 = symbol to define if the option is set
6353 dnl $4 = additional actions to take if the option is set
6354 AC_DEFUN([CF_NO_LEAKS_OPTION],[
6355 AC_MSG_CHECKING(if you want to use $1 for testing)
6356 AC_ARG_WITH($1,
6357         [$2],
6358         [case "x$withval" in
6359         (x|xno) ;;
6360         (*)
6361                 : "${with_cflags:=-g}"
6362                 : "${enable_leaks:=no}"
6363                 with_$1=yes
6364                 AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
6365          $4
6366 ])
6367                 ;;
6368         esac],
6369         [with_$1=])
6370 AC_MSG_RESULT(${with_$1:-no})
6371
6372 case ".$with_cflags" in
6373 (.*-g*)
6374         case .$CFLAGS in
6375         (.*-g*)
6376                 ;;
6377         (*)
6378                 CF_ADD_CFLAGS([-g])
6379                 ;;
6380         esac
6381         ;;
6382 esac
6383 ])dnl
6384 dnl ---------------------------------------------------------------------------
6385 dnl CF_NUMBER_SYNTAX version: 2 updated: 2015/04/17 21:13:04
6386 dnl ----------------
6387 dnl Check if the given variable is a number.  If not, report an error.
6388 dnl $1 is the variable
6389 dnl $2 is the message
6390 AC_DEFUN([CF_NUMBER_SYNTAX],[
6391 if test -n "$1" ; then
6392   case $1 in
6393   ([[0-9]]*)
6394         ;;
6395   (*)
6396         AC_MSG_ERROR($2 is not a number: $1)
6397         ;;
6398   esac
6399 else
6400   AC_MSG_ERROR($2 value is empty)
6401 fi
6402 ])dnl
6403 dnl ---------------------------------------------------------------------------
6404 dnl CF_OBJ_SUBDIR version: 8 updated: 2021/01/01 13:31:04
6405 dnl -------------
6406 dnl Compute the object-directory name from the given model name
6407 AC_DEFUN([CF_OBJ_SUBDIR],
6408 [
6409         case $1 in
6410         (libtool) $2='obj_lo'  ;;
6411         (normal)  $2='objects' ;;
6412         (debug)   $2='obj_g' ;;
6413         (profile) $2='obj_p' ;;
6414         (shared)
6415                 case "$cf_cv_system_name" in
6416                 (cygwin|msys)
6417                         $2='objects' ;;
6418                 (*)
6419                         $2='obj_s' ;;
6420                 esac
6421         esac
6422 ])dnl
6423 dnl ---------------------------------------------------------------------------
6424 dnl CF_OUTPUT_MANPAGE_RENAMES version: 2 updated: 2022/10/22 19:12:31
6425 dnl -------------------------
6426 dnl This runs in the output step to config.status, after man_db.renames has
6427 dnl been generated.
6428 AC_DEFUN([CF_OUTPUT_MANPAGE_RENAMES],
6429 [
6430 AC_REQUIRE([CF_MANPAGE_RENAMES])
6431 if test "$MANPAGE_RENAMES" != no ; then
6432         # Construct a sed-script to perform renaming within man-pages
6433         test -n "$verbose" && echo "creating edit_man.sed"
6434         test ! -d man && mkdir man
6435         FGREP="${FGREP-grep -F}" $SHELL "$srcdir/man/make_sed.sh" "$MANPAGE_RENAMES" >./edit_man.sed
6436 fi
6437 ])dnl
6438 dnl ---------------------------------------------------------------------------
6439 dnl CF_PATHSEP version: 8 updated: 2021/01/01 13:31:04
6440 dnl ----------
6441 dnl Provide a value for the $PATH and similar separator (or amend the value
6442 dnl as provided in autoconf 2.5x).
6443 AC_DEFUN([CF_PATHSEP],
6444 [
6445         AC_MSG_CHECKING(for PATH separator)
6446         case "$cf_cv_system_name" in
6447         (os2*)  PATH_SEPARATOR=';'  ;;
6448         (*)     ${PATH_SEPARATOR:=':'}  ;;
6449         esac
6450 ifelse([$1],,,[$1=$PATH_SEPARATOR])
6451         AC_SUBST(PATH_SEPARATOR)
6452         AC_MSG_RESULT($PATH_SEPARATOR)
6453 ])dnl
6454 dnl ---------------------------------------------------------------------------
6455 dnl CF_PATH_PROG version: 12 updated: 2021/01/02 09:31:20
6456 dnl ------------
6457 dnl Check for a given program, defining corresponding symbol.
6458 dnl     $1 = environment variable, which is suffixed by "_PATH" in the #define.
6459 dnl     $2 = program name to find.
6460 dnl     $3 = optional list of additional program names to test.
6461 dnl $4 = $PATH
6462 dnl
6463 dnl If there is more than one token in the result, #define the remaining tokens
6464 dnl to $1_ARGS.  We need this for 'install' in particular.
6465 dnl
6466 dnl FIXME: we should allow this to be overridden by environment variables
6467 dnl
6468 AC_DEFUN([CF_PATH_PROG],[
6469 AC_REQUIRE([CF_PATHSEP])
6470 test -z "[$]$1" && $1="$2"
6471 AC_PATH_PROGS($1,[$]$1 $2 ifelse($3,,,$3),[$]$1, ifelse($4,,,$4))
6472
6473 cf_path_prog=""
6474 cf_path_args=""
6475 IFS="${IFS:-    }"; cf_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR"
6476 for cf_temp in $ac_cv_path_$1
6477 do
6478         if test -z "$cf_path_prog" ; then
6479                 if test "$with_full_paths" = yes ; then
6480                         CF_PATH_SYNTAX(cf_temp,break)
6481                         cf_path_prog="$cf_temp"
6482                 else
6483                         cf_path_prog="`basename "$cf_temp"`"
6484                 fi
6485         elif test -z "$cf_path_args" ; then
6486                 cf_path_args="$cf_temp"
6487         else
6488                 cf_path_args="$cf_path_args $cf_temp"
6489         fi
6490 done
6491 IFS="$cf_save_ifs"
6492
6493 if test -n "$cf_path_prog" ; then
6494         CF_MSG_LOG(defining path for ${cf_path_prog})
6495         AC_DEFINE_UNQUOTED($1_PATH,"$cf_path_prog",Define to pathname $1)
6496         test -n "$cf_path_args" && AC_DEFINE_UNQUOTED($1_ARGS,"$cf_path_args",Define to provide args for $1)
6497 fi
6498 ])dnl
6499 dnl ---------------------------------------------------------------------------
6500 dnl CF_PATH_SYNTAX version: 18 updated: 2020/12/31 18:40:20
6501 dnl --------------
6502 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
6503 dnl begins with one of the prefix/exec_prefix variables, and then again if the
6504 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
6505 dnl delayed evaluation of those symbols.
6506 AC_DEFUN([CF_PATH_SYNTAX],[
6507 if test "x$prefix" != xNONE; then
6508         cf_path_syntax="$prefix"
6509 else
6510         cf_path_syntax="$ac_default_prefix"
6511 fi
6512
6513 case ".[$]$1" in
6514 (.\[$]\(*\)*|.\'*\'*)
6515         ;;
6516 (..|./*|.\\*)
6517         ;;
6518 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
6519         ;;
6520 (.\[$]\{*prefix\}*|.\[$]\{*dir\}*)
6521         eval $1="[$]$1"
6522         case ".[$]$1" in
6523         (.NONE/*)
6524                 $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
6525                 ;;
6526         esac
6527         ;;
6528 (.no|.NONE/*)
6529         $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
6530         ;;
6531 (*)
6532         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
6533         ;;
6534 esac
6535 ])dnl
6536 dnl ---------------------------------------------------------------------------
6537 dnl CF_PKG_CONFIG version: 12 updated: 2021/10/10 20:18:09
6538 dnl -------------
6539 dnl Check for the package-config program, unless disabled by command-line.
6540 dnl
6541 dnl Sets $PKG_CONFIG to the pathname of the pkg-config program.
6542 AC_DEFUN([CF_PKG_CONFIG],
6543 [
6544 AC_MSG_CHECKING(if you want to use pkg-config)
6545 AC_ARG_WITH(pkg-config,
6546         [  --with-pkg-config{=path} enable/disable use of pkg-config],
6547         [cf_pkg_config=$withval],
6548         [cf_pkg_config=yes])
6549 AC_MSG_RESULT($cf_pkg_config)
6550
6551 case "$cf_pkg_config" in
6552 (no)
6553         PKG_CONFIG=none
6554         ;;
6555 (yes)
6556         CF_ACVERSION_CHECK(2.52,
6557                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
6558                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
6559         ;;
6560 (*)
6561         PKG_CONFIG=$withval
6562         ;;
6563 esac
6564
6565 test -z "$PKG_CONFIG" && PKG_CONFIG=none
6566 if test "$PKG_CONFIG" != none ; then
6567         CF_PATH_SYNTAX(PKG_CONFIG)
6568 elif test "x$cf_pkg_config" != xno ; then
6569         AC_MSG_WARN(pkg-config is not installed)
6570 fi
6571
6572 AC_SUBST(PKG_CONFIG)
6573 ])dnl
6574 dnl ---------------------------------------------------------------------------
6575 dnl CF_POSIX_C_SOURCE version: 11 updated: 2018/12/31 20:46:17
6576 dnl -----------------
6577 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
6578 dnl
6579 dnl     POSIX.1-1990                            _POSIX_SOURCE
6580 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
6581 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
6582 dnl             Bindings Option
6583 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
6584 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
6585 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
6586 dnl
6587 dnl Parameters:
6588 dnl     $1 is the nominal value for _POSIX_C_SOURCE
6589 AC_DEFUN([CF_POSIX_C_SOURCE],
6590 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
6591
6592 if test "$cf_cv_posix_visible" = no; then
6593
6594 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
6595
6596 cf_save_CFLAGS="$CFLAGS"
6597 cf_save_CPPFLAGS="$CPPFLAGS"
6598
6599 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
6600 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
6601
6602 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
6603         CF_MSG_LOG(if the symbol is already defined go no further)
6604         AC_TRY_COMPILE([#include <sys/types.h>],[
6605 #ifndef _POSIX_C_SOURCE
6606 make an error
6607 #endif],
6608         [cf_cv_posix_c_source=no],
6609         [cf_want_posix_source=no
6610          case .$cf_POSIX_C_SOURCE in
6611          (.[[12]]??*)
6612                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
6613                 ;;
6614          (.2)
6615                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
6616                 cf_want_posix_source=yes
6617                 ;;
6618          (.*)
6619                 cf_want_posix_source=yes
6620                 ;;
6621          esac
6622          if test "$cf_want_posix_source" = yes ; then
6623                 AC_TRY_COMPILE([#include <sys/types.h>],[
6624 #ifdef _POSIX_SOURCE
6625 make an error
6626 #endif],[],
6627                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
6628          fi
6629          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
6630          CFLAGS="$cf_trim_CFLAGS"
6631          CPPFLAGS="$cf_trim_CPPFLAGS"
6632          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
6633          CF_MSG_LOG(if the second compile does not leave our definition intact error)
6634          AC_TRY_COMPILE([#include <sys/types.h>],[
6635 #ifndef _POSIX_C_SOURCE
6636 make an error
6637 #endif],,
6638          [cf_cv_posix_c_source=no])
6639          CFLAGS="$cf_save_CFLAGS"
6640          CPPFLAGS="$cf_save_CPPFLAGS"
6641         ])
6642 ])
6643
6644 if test "$cf_cv_posix_c_source" != no ; then
6645         CFLAGS="$cf_trim_CFLAGS"
6646         CPPFLAGS="$cf_trim_CPPFLAGS"
6647         CF_ADD_CFLAGS($cf_cv_posix_c_source)
6648 fi
6649
6650 fi # cf_cv_posix_visible
6651
6652 ])dnl
6653 dnl ---------------------------------------------------------------------------
6654 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
6655 dnl ----------------
6656 dnl POSIX documents test-macros which an application may set before any system
6657 dnl headers are included to make features available.
6658 dnl
6659 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
6660 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
6661 dnl recent features visible in the system header files unless the application
6662 dnl overrides the corresponding test-macros.  Doing that introduces portability
6663 dnl problems.
6664 dnl
6665 dnl This macro makes a special check for the symbols used for this, to avoid a
6666 dnl conflicting definition.
6667 AC_DEFUN([CF_POSIX_VISIBLE],
6668 [
6669 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
6670 AC_TRY_COMPILE([#include <stdio.h>],[
6671 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
6672         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
6673         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
6674         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
6675 #error conflicting symbols found
6676 #endif
6677 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
6678 ])
6679 ])dnl
6680 dnl ---------------------------------------------------------------------------
6681 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
6682 dnl ------------
6683 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
6684 dnl
6685 dnl $1 = symbol to test
6686 dnl $2 = value (if any) to use for a predefinition
6687 AC_DEFUN([CF_PREDEFINE],
6688 [
6689 AC_MSG_CHECKING(if we must define $1)
6690 AC_TRY_COMPILE([#include <sys/types.h>
6691 ],[
6692 #ifndef $1
6693 make an error
6694 #endif],[cf_result=no],[cf_result=yes])
6695 AC_MSG_RESULT($cf_result)
6696
6697 if test "$cf_result" = yes ; then
6698         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
6699 elif test "x$2" != "x" ; then
6700         AC_MSG_CHECKING(checking for compatible value versus $2)
6701         AC_TRY_COMPILE([#include <sys/types.h>
6702 ],[
6703 #if $1-$2 < 0
6704 make an error
6705 #endif],[cf_result=yes],[cf_result=no])
6706         AC_MSG_RESULT($cf_result)
6707         if test "$cf_result" = no ; then
6708                 # perhaps we can override it - try...
6709                 CPPFLAGS="$CPPFLAGS -D$1=$2"
6710         fi
6711 fi
6712 ])dnl
6713 dnl ---------------------------------------------------------------------------
6714 dnl CF_PRG_RULES version: 2 updated: 2021/01/01 13:31:04
6715 dnl ------------
6716 dnl Append definitions and rules for the given programs to the subdirectory
6717 dnl Makefiles, and the recursion rule for the top-level Makefile.
6718 dnl
6719 dnl parameters
6720 dnl     $1 = script to run
6721 dnl     $2 = list of subdirectories
6722 dnl
6723 dnl variables
6724 dnl     $AWK
6725 AC_DEFUN([CF_PRG_RULES],
6726 [
6727 for cf_dir in $2
6728 do
6729         if test ! -d "$srcdir/$cf_dir" ; then
6730                 continue
6731         elif test -f "$srcdir/$cf_dir/programs" ; then
6732                 $AWK -f $1 "$srcdir/$cf_dir/programs" >>$cf_dir/Makefile
6733         fi
6734 done
6735
6736 ])dnl
6737 dnl ---------------------------------------------------------------------------
6738 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
6739 dnl ----------
6740 dnl Check for archiver "ar".
6741 AC_DEFUN([CF_PROG_AR],[
6742 AC_CHECK_TOOL(AR, ar, ar)
6743 ])
6744 dnl ---------------------------------------------------------------------------
6745 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
6746 dnl -----------
6747 dnl Check for awk, ensure that the check found something.
6748 AC_DEFUN([CF_PROG_AWK],
6749 [
6750 AC_PROG_AWK
6751 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
6752 ])dnl
6753 dnl ---------------------------------------------------------------------------
6754 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
6755 dnl ----------
6756 dnl standard check for CC, plus followup sanity checks
6757 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
6758 AC_DEFUN([CF_PROG_CC],[
6759 CF_ACVERSION_CHECK(2.53,
6760         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
6761          AC_REQUIRE([AC_PROG_CC])],
6762         [])
6763 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
6764 CF_GCC_VERSION
6765 CF_ACVERSION_CHECK(2.52,
6766         [AC_PROG_CC_STDC],
6767         [CF_ANSI_CC_REQD])
6768 CF_CC_ENV_FLAGS
6769 ])dnl
6770 dnl ---------------------------------------------------------------------------
6771 dnl CF_PROG_CC_C_O version: 6 updated: 2021/01/01 13:31:04
6772 dnl --------------
6773 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
6774 dnl the output file can be renamed, and allows for a shell variable that can
6775 dnl be used later.  The parameter is either CC or CXX.  The result is the
6776 dnl cache variable:
6777 dnl     $cf_cv_prog_CC_c_o
6778 dnl     $cf_cv_prog_CXX_c_o
6779 dnl
6780 dnl $1 = compiler
6781 dnl $2 = compiler options, if any
6782 AC_DEFUN([CF_PROG_CC_C_O],
6783 [AC_REQUIRE([AC_PROG_CC])dnl
6784 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
6785 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
6786 [
6787 cat > conftest.$ac_ext <<CF_EOF
6788 int main(void)
6789 {
6790         ${cf_cv_main_return:-return}(0);
6791 }
6792 CF_EOF
6793 # We do the test twice because some compilers refuse to overwrite an
6794 # existing .o file with -o, though they will create one.
6795 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
6796 if AC_TRY_EVAL(ac_try) &&
6797   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
6798 then
6799   eval cf_cv_prog_$1_c_o=yes
6800 else
6801   eval cf_cv_prog_$1_c_o=no
6802 fi
6803 rm -rf ./conftest*
6804 ])dnl
6805 if test "$cf_cv_prog_$1_c_o" = yes; then
6806   AC_MSG_RESULT([yes])
6807 else
6808   AC_MSG_RESULT([no])
6809 fi
6810 ])dnl
6811 dnl ---------------------------------------------------------------------------
6812 dnl CF_PROG_GNAT version: 12 updated: 2021/01/02 17:09:14
6813 dnl ------------
6814 dnl Check for gnat/gnatmake/etc, ensure that the toolset is complete.
6815 AC_DEFUN([CF_PROG_GNAT],[
6816 for cf_prog_gnat in gnat gnatmake gprconfig gprbuild
6817 do
6818         CF_UPPER(cf_upper_prog_gnat,${cf_prog_gnat})
6819
6820         unset ac_cv_path_cf_TEMP_gnat
6821         unset cf_TEMP_gnat
6822         AC_PATH_PROG(cf_TEMP_gnat,$cf_prog_gnat,no)
6823         eval "cf_cv_PATH_$cf_upper_prog_gnat=[$]ac_cv_path_cf_TEMP_gnat"
6824
6825         if test "x$cf_TEMP_gnat" != xno; then
6826                 unset cf_cv_gnat_version
6827                 unset cf_TEMP_gnat
6828                 CF_GNAT_VERSION(cf_TEMP_gnat,$cf_prog_gnat)
6829         fi
6830         eval "cf_cv_VERSION_$cf_upper_prog_gnat=[$]cf_TEMP_gnat"
6831
6832         unset cf_TEMP_gnat
6833         unset cf_cv_gnat_version
6834         unset ac_cv_path_cf_TEMP_gnat
6835 done
6836
6837 if test "x$cf_cv_VERSION_GNATMAKE" = "xno"; then
6838         cf_ada_make=
6839         cf_cv_prog_gnat_correct=no
6840 else
6841         cf_ada_make=gnatmake
6842         if test "x$cf_cv_VERSION_GPRCONFIG" = "xno"; then
6843                 # gprconfig is newer than gnatmake; we can continue...
6844                 cf_ada_config="##"
6845         else
6846                 rm -rf ./conftest* ./*~conftest*
6847                 if mkdir conftest.src
6848                 then
6849                         cf_ada_config=""
6850                         cd conftest.src
6851                         for cf_gprconfig in Ada C
6852                         do
6853                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
6854                                 if test "$cf_gprconfig" = C
6855                                 then
6856                                         for cf_gprconfig_param in \
6857                                                 "$cf_gprconfig,,,,GNATGCC" \
6858                                                 "$cf_gprconfig,,,,GCC" \
6859                                                 "$cf_gprconfig"
6860                                         do
6861                                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6862                                                 test -n "$cf_gprconfig_value" && break
6863                                         done
6864                                 else
6865                                         cf_gprconfig_param=$cf_gprconfig
6866                                         cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6867                                 fi
6868                                 if test -n "$cf_gprconfig_value"
6869                                 then
6870                                         eval "cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value"
6871                                         AC_MSG_RESULT($cf_gprconfig_value)
6872                                 else
6873                                         AC_MSG_RESULT(missing)
6874                                         cf_ada_config="#"
6875                                         break
6876                                 fi
6877                         done
6878                         cd ..
6879                         rm -rf ./conftest* ./*~conftest*
6880                 fi
6881         fi
6882         if test "x$cf_ada_config" != "x#"
6883         then
6884                 CF_GNAT_VERSION
6885                 CF_CHECK_GNAT_VERSION
6886                 AC_CHECK_PROG(M4_exists, m4, yes, no)
6887                 if test "$ac_cv_prog_M4_exists" = no; then
6888                         cf_cv_prog_gnat_correct=no
6889                         AC_MSG_WARN(Ada95 binding required program m4 not found. Ada95 binding disabled)
6890                 fi
6891                 if test "$cf_cv_prog_gnat_correct" = yes; then
6892                         AC_MSG_CHECKING(if GNAT works)
6893                         CF_GNAT_TRY_RUN([procedure conftest;],
6894 [with Text_IO;
6895 with GNAT.OS_Lib;
6896 procedure conftest is
6897 begin
6898    Text_IO.Put ("Hello World");
6899    Text_IO.New_Line;
6900    GNAT.OS_Lib.OS_Exit (0);
6901 end conftest;],
6902 [cf_cv_prog_gnat_correct=yes],
6903 [cf_cv_prog_gnat_correct=no])
6904                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
6905                 fi
6906         else
6907                 cf_cv_prog_gnat_correct=no
6908         fi
6909 fi
6910
6911 AC_SUBST(cf_ada_make)
6912 AC_SUBST(cf_ada_config)
6913 AC_SUBST(cf_ada_config_Ada)
6914 AC_SUBST(cf_ada_config_C)
6915 ])dnl
6916 dnl ---------------------------------------------------------------------------
6917 dnl CF_PROG_INSTALL version: 10 updated: 2021/01/04 19:33:05
6918 dnl ---------------
6919 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
6920 dnl misc/tabset install won't work properly.  Usually this happens only when
6921 dnl using the fallback mkinstalldirs script
6922 AC_DEFUN([CF_PROG_INSTALL],
6923 [AC_PROG_INSTALL
6924 case $INSTALL in
6925 (/*)
6926         ;;
6927 (*)
6928         CF_DIRNAME(cf_dir,$INSTALL)
6929         test -z "$cf_dir" && cf_dir=.
6930         INSTALL="`cd \"$cf_dir\" && pwd`"/"`echo "$INSTALL" | sed -e 's%^.*/%%'`"
6931         ;;
6932 esac
6933 ])dnl
6934 dnl ---------------------------------------------------------------------------
6935 dnl CF_PROG_LDCONFIG version: 5 updated: 2015/04/18 08:56:57
6936 dnl ----------------
6937 dnl Check for ldconfig, needed to fixup shared libraries that would be built
6938 dnl and then used in the install.
6939 AC_DEFUN([CF_PROG_LDCONFIG],[
6940 if test "$cross_compiling" = yes ; then
6941         LDCONFIG=:
6942 else
6943         case "$cf_cv_system_name" in
6944         (dragonfly*|mirbsd*|freebsd*)
6945                 test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
6946                 ;;
6947         (*) LDPATH=$PATH:/sbin:/usr/sbin
6948                 AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
6949                 ;;
6950         esac
6951 fi
6952 AC_SUBST(LDCONFIG)
6953 ])dnl
6954 dnl ---------------------------------------------------------------------------
6955 dnl CF_PROG_LINT version: 5 updated: 2022/08/20 15:44:13
6956 dnl ------------
6957 AC_DEFUN([CF_PROG_LINT],
6958 [
6959 AC_CHECK_PROGS(LINT, lint cppcheck splint)
6960 case "x$LINT" in
6961 (xcppcheck|x*/cppcheck)
6962         test -z "$LINT_OPTS" && LINT_OPTS="--enable=all"
6963         ;;
6964 esac
6965 AC_SUBST(LINT_OPTS)
6966 AC_SUBST(LINT_LIBS)
6967 ])dnl
6968 dnl ---------------------------------------------------------------------------
6969 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
6970 dnl ------------
6971 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
6972 dnl option if it is supported.
6973 AC_DEFUN([CF_PROG_LN_S],[
6974 AC_PROG_LN_S
6975 AC_MSG_CHECKING(if $LN_S -f options work)
6976
6977 rm -f conf$$.src conf$$dst
6978 echo >conf$$.dst
6979 echo first >conf$$.src
6980 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
6981         cf_prog_ln_sf=yes
6982 else
6983         cf_prog_ln_sf=no
6984 fi
6985 rm -f conf$$.dst conf$$src
6986 AC_MSG_RESULT($cf_prog_ln_sf)
6987
6988 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
6989 ])dnl
6990 dnl ---------------------------------------------------------------------------
6991 dnl CF_REGEX version: 18 updated: 2021/01/01 16:53:59
6992 dnl --------
6993 dnl Attempt to determine if we've got one of the flavors of regular-expression
6994 dnl code that we can support.
6995 AC_DEFUN([CF_REGEX],
6996 [
6997
6998 cf_regex_func=no
6999 cf_regex_libs=
7000 case "$host_os" in
7001 (mingw*)
7002         # -lsystre -ltre -lintl -liconv
7003         AC_CHECK_LIB(systre,regcomp,[
7004                 AC_CHECK_LIB(iconv,libiconv_open,[CF_ADD_LIB(iconv)])
7005                 AC_CHECK_LIB(intl,libintl_gettext,[CF_ADD_LIB(intl)])
7006                 AC_CHECK_LIB(tre,tre_regcomp,[CF_ADD_LIB(tre)])
7007                 CF_ADD_LIB(systre)
7008                 cf_regex_func=regcomp
7009         ],[
7010                 AC_CHECK_LIB(gnurx,regcomp,[
7011                         CF_ADD_LIB(gnurx)
7012                         cf_regex_func=regcomp])
7013         ])
7014         ;;
7015 (*)
7016         cf_regex_libs="regex re"
7017         AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
7018                 for cf_regex_lib in $cf_regex_libs
7019                 do
7020                         AC_CHECK_LIB($cf_regex_lib,regcomp,[
7021                                         CF_ADD_LIB($cf_regex_lib)
7022                                         cf_regex_func=regcomp
7023                                         break])
7024                 done
7025         ])
7026         ;;
7027 esac
7028
7029 if test "$cf_regex_func" = no ; then
7030         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
7031                 AC_CHECK_LIB(gen,compile,[
7032                                 CF_ADD_LIB(gen)
7033                                 cf_regex_func=compile])])
7034 fi
7035
7036 if test "$cf_regex_func" = no ; then
7037         AC_MSG_WARN(cannot find regular expression library)
7038 fi
7039
7040 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
7041
7042 cf_cv_regex_hdrs=no
7043 case "$cf_regex_func" in
7044 (compile)
7045         for cf_regex_hdr in regexp.h regexpr.h
7046         do
7047                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
7048                         char *p = compile("", "", "", 0);
7049                         int x = step("", "");
7050                         (void)p;
7051                         (void)x;
7052                 ],[
7053                         cf_cv_regex_hdrs=$cf_regex_hdr
7054                         break
7055                 ])
7056         done
7057         ;;
7058 (*)
7059         for cf_regex_hdr in regex.h
7060         do
7061                 AC_TRY_LINK([#include <sys/types.h>
7062 #include <$cf_regex_hdr>],[
7063                         regex_t *p = 0;
7064                         int x = regcomp(p, "", 0);
7065                         int y = regexec(p, "", 0, 0, 0);
7066                         (void)x;
7067                         (void)y;
7068                         regfree(p);
7069                 ],[
7070                         cf_cv_regex_hdrs=$cf_regex_hdr
7071                         break
7072                 ])
7073         done
7074         ;;
7075 esac
7076
7077 ])
7078
7079 case "$cf_cv_regex_hdrs" in
7080         (no)            AC_MSG_WARN(no regular expression header found) ;;
7081         (regex.h)       AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;;
7082         (regexp.h)      AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;;
7083         (regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
7084 esac
7085 ])dnl
7086 dnl ---------------------------------------------------------------------------
7087 dnl CF_REMOVE_CFLAGS version: 3 updated: 2021/09/05 17:25:40
7088 dnl ----------------
7089 dnl Remove a given option from CFLAGS/CPPFLAGS
7090 dnl $1 = option to remove
7091 dnl $2 = variable to update
7092 dnl $3 = nonempty to allow verbose message
7093 define([CF_REMOVE_CFLAGS],
7094 [
7095 cf_tmp_cflag=`echo "x$1" | sed -e 's/^.//' -e 's/=.*//'`
7096 while true
7097 do
7098         cf_old_cflag=`echo "x[$]$2" | sed -e 's/^.//' -e 's/[[  ]][[    ]]*-/ -/g' -e "s%$cf_tmp_cflag\\(=[[^   ]][[^   ]]*\\)\?%%" -e 's/^[[   ]]*//' -e 's%[[ ]][[ ]]*-D% -D%g' -e 's%[[ ]][[ ]]*-I% -I%g'`
7099         test "[$]$2" != "$cf_old_cflag" || break
7100         ifelse([$3],,,[CF_VERBOSE(removing old option $1 from $2)])
7101         $2="$cf_old_cflag"
7102 done
7103 ])dnl
7104 dnl ---------------------------------------------------------------------------
7105 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
7106 dnl ----------------
7107 dnl Remove all -U and -D options that refer to the given symbol from a list
7108 dnl of C compiler options.  This works around the problem that not all
7109 dnl compilers process -U and -D options from left-to-right, so a -U option
7110 dnl cannot be used to cancel the effect of a preceding -D option.
7111 dnl
7112 dnl $1 = target (which could be the same as the source variable)
7113 dnl $2 = source (including '$')
7114 dnl $3 = symbol to remove
7115 define([CF_REMOVE_DEFINE],
7116 [
7117 $1=`echo "$2" | \
7118         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
7119                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
7120 ])dnl
7121 dnl ---------------------------------------------------------------------------
7122 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
7123 dnl -------------
7124 dnl Remove the given library from the symbol
7125 dnl
7126 dnl $1 = target (which could be the same as the source variable)
7127 dnl $2 = source (including '$')
7128 dnl $3 = library to remove
7129 define([CF_REMOVE_LIB],
7130 [
7131 # remove $3 library from $2
7132 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
7133 ])dnl
7134 dnl ---------------------------------------------------------------------------
7135 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
7136 dnl ---------------------
7137 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
7138 dnl $1 = name of current macro
7139 define([CF_RESTORE_XTRA_FLAGS],
7140 [
7141 LIBS="$cf_save_LIBS_$1"
7142 CFLAGS="$cf_save_CFLAGS_$1"
7143 CPPFLAGS="$cf_save_CPPFLAGS_$1"
7144 ])dnl
7145 dnl ---------------------------------------------------------------------------
7146 dnl CF_RPATH_HACK version: 13 updated: 2021/01/03 18:30:50
7147 dnl -------------
7148 AC_DEFUN([CF_RPATH_HACK],
7149 [AC_REQUIRE([AC_PROG_FGREP])dnl
7150 AC_REQUIRE([CF_LD_RPATH_OPT])dnl
7151
7152 AC_MSG_CHECKING(for updated LDFLAGS)
7153 if test -n "$LD_RPATH_OPT" ; then
7154         AC_MSG_RESULT(maybe)
7155
7156         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
7157         cf_rpath_list="/usr/lib /lib"
7158         if test "$cf_ldd_prog" != no
7159         then
7160                 cf_rpath_oops=
7161
7162 AC_TRY_LINK([#include <stdio.h>],
7163                 [printf("Hello");],
7164                 [cf_rpath_oops=`"$cf_ldd_prog" "conftest$ac_exeext" | ${FGREP-fgrep} ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
7165                  cf_rpath_list=`"$cf_ldd_prog" "conftest$ac_exeext" | ${FGREP-fgrep} / | sed -e 's%^.*[[        ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
7166
7167                 # If we passed the link-test, but get a "not found" on a given library,
7168                 # this could be due to inept reconfiguration of gcc to make it only
7169                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
7170                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
7171                 # /usr/local libraries.
7172                 if test -n "$cf_rpath_oops"
7173                 then
7174                         for cf_rpath_src in $cf_rpath_oops
7175                         do
7176                                 for cf_rpath_dir in \
7177                                         /usr/local \
7178                                         /usr/pkg \
7179                                         /opt/sfw
7180                                 do
7181                                         if test -f "$cf_rpath_dir/lib/$cf_rpath_src"
7182                                         then
7183                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
7184                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
7185                                                 break
7186                                         fi
7187                                 done
7188                         done
7189                 fi
7190         fi
7191
7192         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
7193
7194         CF_RPATH_HACK_2(LDFLAGS)
7195         CF_RPATH_HACK_2(LIBS)
7196
7197         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
7198 else
7199         AC_MSG_RESULT(no)
7200 fi
7201 AC_SUBST(EXTRA_LDFLAGS)
7202 ])dnl
7203 dnl ---------------------------------------------------------------------------
7204 dnl CF_RPATH_HACK_2 version: 8 updated: 2021/01/01 13:31:04
7205 dnl ---------------
7206 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
7207 dnl EXTRA_LDFLAGS for each -L option found.
7208 dnl
7209 dnl $cf_rpath_list contains a list of directories to ignore.
7210 dnl
7211 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
7212 dnl      but LIBS often has misplaced -L options.
7213 AC_DEFUN([CF_RPATH_HACK_2],
7214 [
7215 CF_VERBOSE(...checking $1 [$]$1)
7216
7217 cf_rpath_dst=
7218 for cf_rpath_src in [$]$1
7219 do
7220         case "$cf_rpath_src" in
7221         (-L*)
7222
7223                 # check if this refers to a directory which we will ignore
7224                 cf_rpath_skip=no
7225                 if test -n "$cf_rpath_list"
7226                 then
7227                         for cf_rpath_item in $cf_rpath_list
7228                         do
7229                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
7230                                 then
7231                                         cf_rpath_skip=yes
7232                                         break
7233                                 fi
7234                         done
7235                 fi
7236
7237                 if test "$cf_rpath_skip" = no
7238                 then
7239                         # transform the option
7240                         if test "$LD_RPATH_OPT" = "-R " ; then
7241                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
7242                         else
7243                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
7244                         fi
7245
7246                         # if we have not already added this, add it now
7247                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
7248                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
7249                         then
7250                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
7251                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
7252                         fi
7253                 fi
7254                 ;;
7255         esac
7256         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
7257 done
7258 $1=$cf_rpath_dst
7259
7260 CF_VERBOSE(...checked $1 [$]$1)
7261 AC_SUBST(EXTRA_LDFLAGS)
7262 ])dnl
7263 dnl ---------------------------------------------------------------------------
7264 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
7265 dnl ------------------
7266 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
7267 dnl and libraries which do not update those variables.
7268 dnl
7269 dnl $1 = name of current macro
7270 define([CF_SAVE_XTRA_FLAGS],
7271 [
7272 cf_save_LIBS_$1="$LIBS"
7273 cf_save_CFLAGS_$1="$CFLAGS"
7274 cf_save_CPPFLAGS_$1="$CPPFLAGS"
7275 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
7276 for cf_X_CFLAGS in $X_CFLAGS
7277 do
7278         case "x$cf_X_CFLAGS" in
7279         x-[[IUD]]*)
7280                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
7281                 ;;
7282         *)
7283                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
7284                 ;;
7285         esac
7286 done
7287 ])dnl
7288 dnl ---------------------------------------------------------------------------
7289 dnl CF_SHARED_OPTS version: 107 updated: 2021/09/04 06:47:34
7290 dnl --------------
7291 dnl --------------
7292 dnl Attempt to determine the appropriate CC/LD options for creating a shared
7293 dnl library.
7294 dnl
7295 dnl Notes:
7296 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
7297 dnl the build-tree, i.e., by making use of the libraries that are compiled in
7298 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
7299 dnl shared library since that can lead to unexpected results at runtime.
7300 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
7301 dnl libraries are compiled in ../../lib
7302 dnl
7303 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
7304 dnl to install symbolic links to the rel/abi versions of shared libraries.
7305 dnl
7306 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
7307 dnl version when making symbolic links.
7308 dnl
7309 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
7310 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
7311 dnl (ex: libncurses.so.<ver>).
7312 dnl
7313 dnl Some loaders leave 'so_locations' lying around.  It is nice to clean up.
7314 AC_DEFUN([CF_SHARED_OPTS],
7315 [
7316         AC_REQUIRE([CF_LD_RPATH_OPT])
7317
7318         RM_SHARED_OPTS=
7319         LOCAL_LDFLAGS=
7320         LOCAL_LDFLAGS2=
7321         LD_SHARED_OPTS=
7322         INSTALL_LIB="-m 644"
7323         : ${rel_builddir:=.}
7324
7325         shlibdir=$libdir
7326         AC_SUBST(shlibdir)
7327
7328         MAKE_DLLS="#"
7329         AC_SUBST(MAKE_DLLS)
7330
7331         cf_cv_do_symlinks=no
7332         cf_ld_rpath_opt=
7333         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
7334
7335         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
7336         AC_ARG_WITH(shlib-version,
7337         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
7338         [test -z "$withval" && withval=auto
7339         case "$withval" in
7340         (yes)
7341                 cf_cv_shlib_version=auto
7342                 ;;
7343         (rel|abi|auto)
7344                 cf_cv_shlib_version=$withval
7345                 ;;
7346         (*)
7347                 AC_MSG_RESULT($withval)
7348                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
7349                 ;;
7350         esac
7351         ],[cf_cv_shlib_version=auto])
7352         AC_MSG_RESULT($cf_cv_shlib_version)
7353
7354         cf_cv_rm_so_locs=no
7355         cf_try_cflags=
7356
7357         # Some less-capable ports of gcc support only -fpic
7358         CC_SHARED_OPTS=
7359
7360         cf_try_fPIC=no
7361         if test "$GCC" = yes
7362         then
7363                 cf_try_fPIC=yes
7364         else
7365                 case "$cf_cv_system_name" in
7366                 (*linux*)       # e.g., PGI compiler
7367                         cf_try_fPIC=yes
7368                         ;;
7369                 esac
7370         fi
7371
7372         if test "$cf_try_fPIC" = yes
7373         then
7374                 AC_MSG_CHECKING(which $CC option to use)
7375                 cf_save_CFLAGS="$CFLAGS"
7376                 for CC_SHARED_OPTS in -fPIC -fpic ''
7377                 do
7378                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
7379                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
7380                 done
7381                 AC_MSG_RESULT($CC_SHARED_OPTS)
7382                 CFLAGS="$cf_save_CFLAGS"
7383         fi
7384
7385         cf_cv_shlib_version_infix=no
7386
7387         case "$cf_cv_system_name" in
7388         (aix4.[3-9]*|aix[[5-7]]*)
7389                 if test "$GCC" = yes; then
7390                         CC_SHARED_OPTS='-Wl,-brtl'
7391                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
7392                 else
7393                         CC_SHARED_OPTS='-brtl'
7394                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
7395                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
7396                 fi
7397                 ;;
7398         (beos*)
7399                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
7400                 ;;
7401         (cygwin*)
7402                 CC_SHARED_OPTS=
7403                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
7404                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
7405                 cf_cv_shlib_version=cygdll
7406                 cf_cv_shlib_version_infix=cygdll
7407                 shlibdir=$bindir
7408                 MAKE_DLLS=
7409                 cat >mk_shared_lib.sh <<-CF_EOF
7410                 #!$SHELL
7411                 SHARED_LIB=\[$]1
7412                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
7413                 shift
7414                 cat <<-EOF
7415                 Linking shared library
7416                 ** SHARED_LIB \[$]SHARED_LIB
7417                 ** IMPORT_LIB \[$]IMPORT_LIB
7418 EOF
7419                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7420 CF_EOF
7421                 chmod +x mk_shared_lib.sh
7422                 ;;
7423         (msys*)
7424                 CC_SHARED_OPTS=
7425                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
7426                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
7427                 cf_cv_shlib_version=msysdll
7428                 cf_cv_shlib_version_infix=msysdll
7429                 shlibdir=$bindir
7430                 MAKE_DLLS=
7431                 cat >mk_shared_lib.sh <<-CF_EOF
7432                 #!$SHELL
7433                 SHARED_LIB=\[$]1
7434                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
7435                 shift
7436                 cat <<-EOF
7437                 Linking shared library
7438                 ** SHARED_LIB \[$]SHARED_LIB
7439                 ** IMPORT_LIB \[$]IMPORT_LIB
7440 EOF
7441                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7442 CF_EOF
7443                 chmod +x mk_shared_lib.sh
7444                 ;;
7445         (darwin*)
7446                 cf_try_cflags="no-cpp-precomp"
7447                 CC_SHARED_OPTS="-dynamic"
7448                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
7449                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
7450                 cf_cv_shlib_version_infix=yes
7451                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
7452                         cf_save_LDFLAGS=$LDFLAGS
7453                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
7454                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
7455                                 LDFLAGS=$cf_save_LDFLAGS])
7456                 if test "$cf_cv_ldflags_search_paths_first" = yes; then
7457                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
7458                 fi
7459                 ;;
7460         (haiku*)
7461                 CF_SHARED_SONAME
7462                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7463                 ;;
7464         (hpux[[7-8]]*)
7465                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
7466                 if test "$GCC" != yes; then
7467                         CC_SHARED_OPTS='+Z'
7468                 fi
7469                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
7470                 INSTALL_LIB="-m 555"
7471                 ;;
7472         (hpux*)
7473                 # (tested with gcc 2.7.2 -- I don't have c89)
7474                 if test "$GCC" = yes; then
7475                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
7476                 else
7477                         CC_SHARED_OPTS='+Z'
7478                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
7479                 fi
7480                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
7481                 # HP-UX shared libraries must be executable, and should be
7482                 # readonly to exploit a quirk in the memory manager.
7483                 INSTALL_LIB="-m 555"
7484                 ;;
7485         (interix*)
7486                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7487                 if test "$cf_cv_shlib_version" = rel; then
7488                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
7489                 else
7490                         cf_shared_soname='`basename $[@]`'
7491                 fi
7492                 CC_SHARED_OPTS=
7493                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
7494                 ;;
7495         (irix*)
7496                 if test "$cf_cv_enable_rpath" = yes ; then
7497                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7498                 fi
7499                 # tested with IRIX 5.2 and 'cc'.
7500                 if test "$GCC" != yes; then
7501                         CC_SHARED_OPTS='-KPIC'
7502                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
7503                 else
7504                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
7505                 fi
7506                 cf_cv_rm_so_locs=yes
7507                 ;;
7508         (linux*|gnu*|k*bsd*-gnu)
7509                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7510                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7511                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7512                 fi
7513                 if test "$cf_cv_enable_rpath" = yes ; then
7514                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7515                 fi
7516                 CF_SHARED_SONAME
7517                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7518                 ;;
7519         (mingw*msvc*)
7520                 cf_cv_shlib_version=msvcdll
7521                 cf_cv_shlib_version_infix=msvcdll
7522                 shlibdir=$bindir
7523                 MAKE_DLLS=
7524                 if test "$DFT_LWR_MODEL" = "shared" ; then
7525                         LOCAL_LDFLAGS="-link -dll"
7526                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7527                         EXTRA_LDFLAGS="-link -dll $EXTRA_LDFLAGS"
7528                 fi
7529                 CC_SHARED_OPTS=
7530                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ ${LD} [$]{CFLAGS}'
7531                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.lib"
7532                 cat >mk_shared_lib.sh <<-CF_EOF
7533                 #!$SHELL
7534                 SHARED_LIB=\[$]1
7535                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.lib/'\`
7536                 shift
7537                 my_ld=\[$]1
7538                 shift
7539                 cat <<-EOF
7540                 Linking shared library
7541                 ** SHARED LIB \$SHARED_LIB
7542                 ** IMPORT_LIB \$IMPORT_LIB
7543 EOF
7544                 args=\$(echo \[$]* | sed -E "s#-l(\w*)#\1.dll.lib#g" | sed -E "s#-L(\w*)#-LIBPATH:\1#g")
7545                 exec \$my_ld -DLL -IMPLIB:"\${IMPORT_LIB}" -OUT:"\${SHARED_LIB}" ${LDFLAGS} \$args
7546                 mv "\${IMPORT_LIB}" "\${IMPORT_LIB}"
7547 CF_EOF
7548                 chmod +x mk_shared_lib.sh
7549                 cat >mk_prog.sh <<-CF_EOF
7550                 #!$SHELL
7551                 shift
7552                 # Ignore first argument (compiler) and use LD (link.exe) unconditionally
7553                 LD="[$]LD"
7554                 clopts=()
7555                 ldopts=("/subsystem:console")
7556                 libs=()
7557                 isdll=0
7558                 while test \[$]# -gt 0; do
7559                         case "\[$]1" in
7560                                 -link)
7561                                         # ignore -link argument
7562                                         ;;
7563                                 -M[[TD]] | -M[[TD]]d)
7564                                         # ignore runtime-library option
7565                                         ;;
7566                                 -dll)
7567                                         isdll=1
7568                                         ;;
7569                                 -W* | -w*)
7570                                         # ignore warnings
7571                                         ;;
7572                                 -D*)
7573                                         clopts+=("\[$]1")
7574                                         ;;
7575                                 -I*)
7576                                         clopts+=("\[$]1")
7577                                         ;;
7578                                 -l*)
7579                                         libs+=("\`echo \"\[$]1\" | sed \"s/^-l//\"\`")
7580                                         ;;
7581                                 -L*)
7582                                         ldopts+=("\`echo \"\[$]1\" | sed \"s/^-L/-LIBPATH:/\"\`")
7583                                         ;;
7584                                 *.obj | *.o)
7585                                         ldopts+=("\[$]1")
7586                                         ;;
7587                                 -Wl,*)
7588                                         for linkarg in \`echo '\[$]1' | sed -e 's/-Wl,//' -e 's/,/ /'\`; do
7589                                                 ldopts+=("\[$]{linkarg}")
7590                                         done
7591                                         ;;
7592                                 *.lib)
7593                                         ldopts+=("\[$]1")
7594                                         ;;
7595                                 -o)
7596                                         shift
7597                                         ldopts+=("-out:\[$]1")
7598                                         ;;
7599                                 *)
7600                                         clopts+=("\[$]1")
7601                                         ldopts+=("\[$]1")
7602                                         ;;
7603                         esac
7604                         shift
7605                 done
7606                 if [[ "\$isdll" -ne 0 ]]; then
7607                         for lib in \[$]{libs[[*]]}; do
7608                                 ldopts+=("\[$]lib.dll.lib")
7609                         done
7610                 else
7611                         for lib in \[$]{libs[[*]]}; do
7612                                 ldopts+=("\[$]lib.lib")
7613                         done
7614                 fi
7615                 cat <<-EOF
7616                 Creating program
7617                 ** ld options:   "\[$]{ldopts[[@]]}"
7618 EOF
7619                 exec \[$]LD \[$]{ldopts[[@]]}
7620 CF_EOF
7621                 chmod +x mk_prog.sh
7622                 LINK_PROGS="$SHELL ${rel_builddir}/mk_prog.sh"
7623                 LINK_TESTS="$SHELL ${rel_builddir}/mk_prog.sh"
7624                 ;;
7625         (mingw*)
7626                 cf_cv_shlib_version=mingw
7627                 cf_cv_shlib_version_infix=mingw
7628                 shlibdir=$bindir
7629                 MAKE_DLLS=
7630                 if test "$DFT_LWR_MODEL" = "shared" ; then
7631                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
7632                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7633                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
7634                 fi
7635                 CC_SHARED_OPTS=
7636                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
7637                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
7638                 cat >mk_shared_lib.sh <<-CF_EOF
7639                 #!$SHELL
7640                 SHARED_LIB=\[$]1
7641                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
7642                 shift
7643                 cat <<-EOF
7644                 Linking shared library
7645                 ** SHARED_LIB \[$]SHARED_LIB
7646                 ** IMPORT_LIB \[$]IMPORT_LIB
7647 EOF
7648                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7649 CF_EOF
7650                 chmod +x mk_shared_lib.sh
7651                 ;;
7652         (openbsd[[2-9]].*|mirbsd*)
7653                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7654                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7655                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7656                 fi
7657                 if test "$cf_cv_enable_rpath" = yes ; then
7658                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7659                 fi
7660                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7661                 CF_SHARED_SONAME
7662                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7663                 ;;
7664         (nskJ*)
7665                 CC_SHARED_OPTS=
7666                 MK_SHARED_LIB='${LD} -Wshared -Weld=-export_all -o $[@]'
7667                 ;;
7668         (nskL*)
7669                 CC_SHARED_OPTS=
7670                 MK_SHARED_LIB='${LD} -Wshared -Wxld=-export_all -o $[@]'
7671                 ;;
7672         (nto-qnx*|openbsd*|freebsd[[12]].*)
7673                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7674                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
7675                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7676                 ;;
7677         (dragonfly*|freebsd*)
7678                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7679                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
7680                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
7681                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
7682                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7683                 fi
7684                 CF_SHARED_SONAME
7685                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7686                 ;;
7687         (netbsd*)
7688                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7689                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
7690                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
7691                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7692                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7693                         if test "$cf_cv_shlib_version" = auto; then
7694                         if test -f /usr/libexec/ld.elf_so; then
7695                                 cf_cv_shlib_version=abi
7696                         else
7697                                 cf_cv_shlib_version=rel
7698                         fi
7699                         fi
7700                         CF_SHARED_SONAME
7701                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
7702                 else
7703                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -o $[@]'
7704                 fi
7705                 ;;
7706         (osf*|mls+*)
7707                 # tested with OSF/1 V3.2 and 'cc'
7708                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
7709                 # link with shared libs).
7710                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
7711                 case "$host_os" in
7712                 (osf4*)
7713                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
7714                         ;;
7715                 esac
7716                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
7717                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7718                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7719                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7720                 fi
7721                 cf_cv_rm_so_locs=yes
7722                 ;;
7723         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
7724                 # tested with osr5.0.5
7725                 if test "$GCC" != yes; then
7726                         CC_SHARED_OPTS='-belf -KPIC'
7727                 fi
7728                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
7729                 if test "$cf_cv_enable_rpath" = yes ; then
7730                         # only way is to set LD_RUN_PATH but no switch for it
7731                         RUN_PATH=$libdir
7732                 fi
7733                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7734                 LINK_PROGS='LD_RUN_PATH=${libdir}'
7735                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
7736                 ;;
7737         (sunos4*)
7738                 # tested with SunOS 4.1.1 and gcc 2.7.0
7739                 if test "$GCC" != yes; then
7740                         CC_SHARED_OPTS='-KPIC'
7741                 fi
7742                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
7743                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7744                 ;;
7745         (solaris2*)
7746                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
7747                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
7748                 if test "$DFT_LWR_MODEL" = "shared" ; then
7749                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
7750                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7751                 fi
7752                 if test "$cf_cv_enable_rpath" = yes ; then
7753                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
7754                 fi
7755                 CF_SHARED_SONAME
7756                 if test "$GCC" != yes; then
7757                         cf_save_CFLAGS="$CFLAGS"
7758                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
7759                         do
7760                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
7761                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\\n");],[break])
7762                         done
7763                         CFLAGS="$cf_save_CFLAGS"
7764                         CC_SHARED_OPTS=$cf_shared_opts
7765                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
7766                 else
7767                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
7768                 fi
7769                 ;;
7770         (sysv5uw7*|unix_sv*)
7771                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
7772                 if test "$GCC" != yes; then
7773                         CC_SHARED_OPTS='-KPIC'
7774                 fi
7775                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
7776                 ;;
7777         (*)
7778                 CC_SHARED_OPTS='unknown'
7779                 MK_SHARED_LIB='echo unknown'
7780                 ;;
7781         esac
7782
7783         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
7784         case "$cf_cv_shlib_version" in
7785         (rel|abi)
7786                 case "$MK_SHARED_LIB" in
7787                 (*'-o $[@]')
7788                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
7789                         ;;
7790                 (*)
7791                         AC_MSG_WARN(ignored --with-shlib-version)
7792                         ;;
7793                 esac
7794                 ;;
7795         esac
7796
7797         if test -n "$cf_try_cflags"
7798         then
7799 cat > conftest.$ac_ext <<EOF
7800 #line __oline__ "${as_me:-configure}"
7801 #include <stdio.h>
7802 int main(int argc, char *argv[[]])
7803 {
7804         printf("hello\\n");
7805         return (argv[[argc-1]] == 0) ;
7806 }
7807 EOF
7808                 cf_save_CFLAGS="$CFLAGS"
7809                 for cf_opt in $cf_try_cflags
7810                 do
7811                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
7812                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
7813                         if AC_TRY_EVAL(ac_compile); then
7814                                 AC_MSG_RESULT(yes)
7815                                 cf_save_CFLAGS="$CFLAGS"
7816                         else
7817                                 AC_MSG_RESULT(no)
7818                         fi
7819                 done
7820                 CFLAGS="$cf_save_CFLAGS"
7821         fi
7822
7823
7824         # RPATH_LIST is a colon-separated list of directories
7825         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
7826         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
7827
7828         test "$cf_cv_rm_so_locs" = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
7829
7830         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
7831         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7832
7833         AC_SUBST(CC_SHARED_OPTS)
7834         AC_SUBST(LD_RPATH_OPT)
7835         AC_SUBST(LD_SHARED_OPTS)
7836         AC_SUBST(MK_SHARED_LIB)
7837         AC_SUBST(RM_SHARED_OPTS)
7838
7839         AC_SUBST(LINK_PROGS)
7840         AC_SUBST(LINK_TESTS)
7841
7842         AC_SUBST(EXTRA_LDFLAGS)
7843         AC_SUBST(LOCAL_LDFLAGS)
7844         AC_SUBST(LOCAL_LDFLAGS2)
7845
7846         AC_SUBST(INSTALL_LIB)
7847         AC_SUBST(RPATH_LIST)
7848 ])dnl
7849 dnl ---------------------------------------------------------------------------
7850 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
7851 dnl ----------------
7852 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
7853 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
7854 dnl option.
7855 dnl
7856 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
7857 dnl If missing, use "rel".
7858 define([CF_SHARED_SONAME],
7859 [
7860         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
7861         if test "$cf_cv_shlib_version" = rel; then
7862                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
7863         else
7864                 cf_cv_shared_soname='`basename $[@]`'
7865         fi
7866 ])
7867 dnl ---------------------------------------------------------------------------
7868 dnl CF_SIGWINCH version: 6 updated: 2021/01/01 13:31:04
7869 dnl -----------
7870 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
7871 dnl programs need this test).
7872 dnl
7873 dnl This is really a Mac OS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
7874 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
7875 dnl winsize declaration is left alone - we may revisit this if Apple choose to
7876 dnl break that part of the interface as well.
7877 AC_DEFUN([CF_SIGWINCH],
7878 [
7879 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
7880         AC_TRY_COMPILE([
7881 #include <sys/types.h>
7882 #include <sys/signal.h>
7883 ],[int x = SIGWINCH; (void)x],
7884         [cf_cv_define_sigwinch=yes],
7885         [AC_TRY_COMPILE([
7886 #undef _XOPEN_SOURCE
7887 #undef _POSIX_SOURCE
7888 #undef _POSIX_C_SOURCE
7889 #include <sys/types.h>
7890 #include <sys/signal.h>
7891 ],[int x = SIGWINCH; (void)x],
7892         [cf_cv_define_sigwinch=maybe],
7893         [cf_cv_define_sigwinch=no])
7894 ])
7895 ])
7896
7897 if test "$cf_cv_define_sigwinch" = maybe ; then
7898 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
7899 cf_cv_fixup_sigwinch=unknown
7900 cf_sigwinch=32
7901 while test "$cf_sigwinch" != 1
7902 do
7903         AC_TRY_COMPILE([
7904 #undef _XOPEN_SOURCE
7905 #undef _POSIX_SOURCE
7906 #undef _POSIX_C_SOURCE
7907 #include <sys/types.h>
7908 #include <sys/signal.h>
7909 ],[
7910 #if SIGWINCH != $cf_sigwinch
7911 make an error
7912 #endif
7913 int x = SIGWINCH; (void)x],
7914         [cf_cv_fixup_sigwinch=$cf_sigwinch
7915          break])
7916
7917 cf_sigwinch="`expr "$cf_sigwinch" - 1`"
7918 done
7919 ])
7920
7921         if test "$cf_cv_fixup_sigwinch" != unknown ; then
7922                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
7923         fi
7924 fi
7925 ])dnl
7926 dnl ---------------------------------------------------------------------------
7927 dnl CF_SIG_ATOMIC_T version: 5 updated: 2020/03/10 18:53:47
7928 dnl ---------------
7929 dnl signal handler, but there are some gcc dependencies in that recommendation.
7930 dnl Try anyway.
7931 AC_DEFUN([CF_SIG_ATOMIC_T],
7932 [
7933 AC_MSG_CHECKING(for signal global datatype)
7934 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
7935         for cf_type in \
7936                 "volatile sig_atomic_t" \
7937                 "sig_atomic_t" \
7938                 "int"
7939         do
7940         AC_TRY_COMPILE([
7941 #include <sys/types.h>
7942 #include <signal.h>
7943 #include <stdio.h>
7944
7945 extern $cf_type x;
7946 $cf_type x;
7947 static void handler(int sig)
7948 {
7949         (void)sig;
7950         x = 5;
7951 }],
7952                 [signal(SIGINT, handler);
7953                  x = 1],
7954                 [cf_cv_sig_atomic_t=$cf_type],
7955                 [cf_cv_sig_atomic_t=no])
7956                 test "$cf_cv_sig_atomic_t" != no && break
7957         done
7958         ])
7959 AC_MSG_RESULT($cf_cv_sig_atomic_t)
7960 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
7961 ])dnl
7962 dnl ---------------------------------------------------------------------------
7963 dnl CF_SIZECHANGE version: 18 updated: 2021/09/04 06:35:04
7964 dnl -------------
7965 dnl Check for definitions & structures needed for window size-changing
7966 dnl
7967 dnl https://stackoverflow.com/questions/18878141/difference-between-structures-ttysize-and-winsize/50769952#50769952
7968 AC_DEFUN([CF_SIZECHANGE],
7969 [
7970 AC_REQUIRE([CF_STRUCT_TERMIOS])
7971 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
7972         cf_cv_sizechange=unknown
7973         cf_save_CPPFLAGS="$CPPFLAGS"
7974
7975 for cf_opts in "" "NEED_PTEM_H"
7976 do
7977
7978         CPPFLAGS="$cf_save_CPPFLAGS"
7979         if test -n "$cf_opts"
7980         then
7981                 CF_APPEND_TEXT(CPPFLAGS,-D$cf_opts)
7982         fi
7983         AC_TRY_COMPILE([#include <sys/types.h>
7984 #ifdef HAVE_TERMIOS_H
7985 #include <termios.h>
7986 #else
7987 #ifdef HAVE_TERMIO_H
7988 #include <termio.h>
7989 #endif
7990 #endif
7991
7992 #ifdef NEED_PTEM_H
7993 /* This is a workaround for SCO:  they neglected to define struct winsize in
7994  * termios.h -- it is only in termio.h and ptem.h
7995  */
7996 #include <sys/stream.h>
7997 #include <sys/ptem.h>
7998 #endif
7999
8000 #ifdef HAVE_SYS_IOCTL_H
8001 #include <sys/ioctl.h>
8002 #endif
8003 ],[
8004 #ifdef TIOCGSIZE
8005         struct ttysize win;     /* SunOS 3.0... */
8006         int y = win.ts_lines = 2;
8007         int x = win.ts_cols = 1;
8008         (void)y;
8009         (void)x;
8010 #else
8011 #ifdef TIOCGWINSZ
8012         struct winsize win;     /* everything else */
8013         int y = win.ws_row = 2;
8014         int x = win.ws_col = 1;
8015         (void)y;
8016         (void)x;
8017 #else
8018         no TIOCGSIZE or TIOCGWINSZ
8019 #endif /* TIOCGWINSZ */
8020 #endif /* TIOCGSIZE */
8021         ],
8022         [cf_cv_sizechange=yes],
8023         [cf_cv_sizechange=no])
8024
8025         CPPFLAGS="$cf_save_CPPFLAGS"
8026         if test "$cf_cv_sizechange" = yes ; then
8027                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
8028                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
8029                 break
8030         fi
8031 done
8032 ])
8033 if test "$cf_cv_sizechange" != no ; then
8034         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechange declarations are provided])
8035         case "$cf_cv_sizechange" in
8036         (NEED*)
8037                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
8038                 ;;
8039         esac
8040 fi
8041 ])dnl
8042 dnl ---------------------------------------------------------------------------
8043 dnl CF_SRC_MODULES version: 33 updated: 2021/01/01 13:31:04
8044 dnl --------------
8045 dnl For each parameter, test if the source-directory exists, and if it contains
8046 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
8047 dnl use in CF_LIB_RULES.
8048 dnl
8049 dnl This uses the configured value to make the lists SRC_SUBDIRS and
8050 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
8051 AC_DEFUN([CF_SRC_MODULES],
8052 [
8053 AC_REQUIRE([CF_CHECK_GNAT_VERSION])
8054 AC_MSG_CHECKING(for src modules)
8055
8056 # dependencies and linker-arguments for test-programs
8057 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
8058 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
8059 if test "$DFT_LWR_MODEL" = "libtool"; then
8060         TEST_ARGS="${TEST_DEPS}"
8061         TEST_ARG2="${TEST_DEP2}"
8062 else
8063         TEST_ARGS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
8064         TEST_ARG2="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARG2"
8065 fi
8066
8067 PC_MODULES_TO_MAKE="ncurses${USE_ARG_SUFFIX}"
8068 cf_cv_src_modules=
8069 for cf_dir in $1
8070 do
8071         if test -f "$srcdir/$cf_dir/modules" ; then
8072
8073                 # We may/may not have tack in the distribution, though the
8074                 # makefile is.
8075                 if test "$cf_dir" = tack ; then
8076                         if test "x$cf_with_tack" != "xyes"; then
8077                                 continue
8078                         fi
8079                 fi
8080
8081                 if test -z "$cf_cv_src_modules"; then
8082                         cf_cv_src_modules=$cf_dir
8083                 else
8084                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
8085                 fi
8086
8087                 # Make the ncurses_cfg.h file record the library interface files as
8088                 # well.  These are header files that are the same name as their
8089                 # directory.  Ncurses is the only library that does not follow
8090                 # that pattern.
8091                 if test "$cf_dir" = tack ; then
8092                         continue
8093                 elif test -f "$srcdir/${cf_dir}/${cf_dir}.h" ; then
8094                         CF_UPPER(cf_have_include,$cf_dir)
8095                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
8096                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
8097                         CF_MAP_LIB_BASENAME(TEST_ROOT,$cf_dir)
8098                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEPS"
8099                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEP2"
8100                         if test "$DFT_LWR_MODEL" = "libtool"; then
8101                                 TEST_ARGS="${TEST_DEPS}"
8102                                 TEST_ARG2="${TEST_DEP2}"
8103                         else
8104                                 TEST_ARGS="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARGS"
8105                                 TEST_ARG2="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARG2"
8106                         fi
8107                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${USE_ARG_SUFFIX}"
8108                 fi
8109         fi
8110 done
8111 AC_MSG_RESULT($cf_cv_src_modules)
8112
8113 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
8114 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
8115
8116 AC_SUBST(TEST_ARGS)
8117 AC_SUBST(TEST_DEPS)
8118
8119 AC_SUBST(TEST_ARG2)
8120 AC_SUBST(TEST_DEP2)
8121
8122 SRC_SUBDIRS=
8123 if test "x$cf_with_manpages" != xno ; then
8124         SRC_SUBDIRS="$SRC_SUBDIRS man"
8125 fi
8126 SRC_SUBDIRS="$SRC_SUBDIRS include"
8127 for cf_dir in $cf_cv_src_modules
8128 do
8129         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
8130 done
8131 if test "x$cf_with_tests" != "xno" ; then
8132         SRC_SUBDIRS="$SRC_SUBDIRS test"
8133 fi
8134 # always make this, to install the ncurses-config script
8135 SRC_SUBDIRS="$SRC_SUBDIRS misc"
8136 if test "$cf_with_cxx_binding" != no; then
8137         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${USE_ARG_SUFFIX}"
8138         SRC_SUBDIRS="$SRC_SUBDIRS c++"
8139 fi
8140
8141 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
8142 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
8143
8144 AC_SUBST(PC_MODULES_TO_MAKE)
8145
8146 ADA_SUBDIRS=
8147 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f "$srcdir/Ada95/Makefile.in" ; then
8148         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
8149         ADA_SUBDIRS="gen src"
8150         if test "x$cf_with_tests" != "xno" ; then
8151                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
8152         fi
8153 fi
8154
8155 SUB_MAKEFILES=
8156 for cf_dir in $SRC_SUBDIRS
8157 do
8158         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
8159 done
8160
8161 if test -n "$ADA_SUBDIRS"; then
8162         for cf_dir in $ADA_SUBDIRS
8163         do
8164                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
8165         done
8166         AC_SUBST(ADA_SUBDIRS)
8167 fi
8168 ])dnl
8169 dnl ---------------------------------------------------------------------------
8170 dnl CF_STDCPP_LIBRARY version: 12 updated: 2021/01/01 13:31:04
8171 dnl -----------------
8172 dnl Check for -lstdc++, which is GNU's standard C++ library.
8173 dnl If $CXXLIBS is set, add that to the libraries used for test-linking.
8174 dnl If -lstdc++ was not already added to $LIBS or $CXXLIBS, and is needed,
8175 dnl add it to $CXXLIBS.
8176 AC_DEFUN([CF_STDCPP_LIBRARY],
8177 [
8178 if test -n "$GXX" ; then
8179
8180         cf_save="$LIBS"
8181         LIBS="$LIBS $CXXLIBS"
8182         AC_MSG_CHECKING(if we already have C++ library)
8183         AC_TRY_LINK([
8184                         #include <iostream>],[
8185                         std::cout << "Hello World!" << std::endl;],
8186                 [cf_have_libstdcpp=yes],
8187                 [cf_have_libstdcpp=no])
8188         AC_MSG_RESULT($cf_have_libstdcpp)
8189         LIBS="$cf_save"
8190
8191         if test "$cf_have_libstdcpp" != yes
8192         then
8193                 case "$cf_cv_system_name" in
8194                 (os2*)
8195                         if test -z "`g++ -dM -E - < /dev/null | grep __KLIBC__`"; then
8196                                 cf_stdcpp_libname=stdcpp
8197                         else
8198                                 cf_stdcpp_libname=stdc++
8199                         fi
8200                         ;;
8201                 (*)
8202                         cf_stdcpp_libname=stdc++
8203                         ;;
8204                 esac
8205
8206                 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
8207                         cf_save="$LIBS"
8208                         LIBS="$LIBS $CXXLIBS"
8209                         CF_ADD_LIB($cf_stdcpp_libname)
8210                 AC_TRY_LINK([
8211                                 #include <iostream>],[
8212                                 std::cout << "Hello World!" << std::endl;],
8213                         [cf_cv_libstdcpp=yes],
8214                         [cf_cv_libstdcpp=no])
8215                         LIBS="$cf_save"
8216                 ])
8217                 test "$cf_cv_libstdcpp" = yes && { CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS) }
8218         fi
8219 fi
8220 ])dnl
8221 dnl ---------------------------------------------------------------------------
8222 dnl CF_STRIP_G_OPT version: 4 updated: 2021/01/02 09:31:20
8223 dnl --------------
8224 dnl     Remove "-g" option from the compiler options
8225 AC_DEFUN([CF_STRIP_G_OPT],
8226 [$1=`echo "${$1}" | CF__SED_TRIMBLANKS(-e 's%-g %%' -e 's%-g$%%')`])dnl
8227 dnl ---------------------------------------------------------------------------
8228 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
8229 dnl -------------------
8230 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
8231 dnl do this if we've found the sigaction function.
8232 AC_DEFUN([CF_STRUCT_SIGACTION],[
8233 AC_REQUIRE([CF_XOPEN_SOURCE])
8234
8235 if test "$ac_cv_func_sigaction" = yes; then
8236 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
8237 AC_TRY_COMPILE([
8238 #include <sys/types.h>
8239 #include <signal.h>],
8240         [struct sigaction act],
8241         [sigact_bad=no],
8242         [
8243 AC_TRY_COMPILE([
8244 #define _POSIX_SOURCE
8245 #include <sys/types.h>
8246 #include <signal.h>],
8247         [struct sigaction act],
8248         [sigact_bad=yes
8249          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
8250          [sigact_bad=unknown])])
8251 AC_MSG_RESULT($sigact_bad)
8252 fi
8253 ])dnl
8254 dnl ---------------------------------------------------------------------------
8255 dnl CF_STRUCT_TERMIOS version: 11 updated: 2020/03/19 20:46:13
8256 dnl -----------------
8257 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
8258 AC_DEFUN([CF_STRUCT_TERMIOS],[
8259 AC_REQUIRE([CF_XOPEN_SOURCE])
8260
8261 AC_CHECK_HEADERS( \
8262 termio.h \
8263 termios.h \
8264 unistd.h \
8265 sys/ioctl.h \
8266 sys/termio.h \
8267 )
8268
8269 if test "$ac_cv_header_termios_h" = yes ; then
8270         case "$CFLAGS $CPPFLAGS" in
8271         (*-D_POSIX_SOURCE*)
8272                 termios_bad=dunno ;;
8273         (*)     termios_bad=maybe ;;
8274         esac
8275         if test "$termios_bad" = maybe ; then
8276         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
8277         AC_TRY_COMPILE([#include <termios.h>],
8278                 [struct termios foo; int x = foo.c_iflag = 1; (void)x],
8279                 termios_bad=no, [
8280                 AC_TRY_COMPILE([
8281 #define _POSIX_SOURCE
8282 #include <termios.h>],
8283                         [struct termios foo; int x = foo.c_iflag = 2; (void)x],
8284                         termios_bad=unknown,
8285                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
8286                         ])
8287         AC_MSG_RESULT($termios_bad)
8288         fi
8289 fi
8290 ])dnl
8291 dnl ---------------------------------------------------------------------------
8292 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
8293 dnl --------------
8294 dnl Construct a search-list for a nonstandard header/lib-file
8295 dnl     $1 = the variable to return as result
8296 dnl     $2 = the package name
8297 dnl     $3 = the subdirectory, e.g., bin, include or lib
8298 AC_DEFUN([CF_SUBDIR_PATH],
8299 [
8300 $1=
8301
8302 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
8303
8304 for cf_subdir_prefix in \
8305         /usr \
8306         /usr/local \
8307         /usr/pkg \
8308         /opt \
8309         /opt/local \
8310         [$]HOME
8311 do
8312         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
8313 done
8314 ])dnl
8315 dnl ---------------------------------------------------------------------------
8316 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
8317 dnl -----------
8318 dnl     Shorthand macro for substituting things that the user may override
8319 dnl     with an environment variable.
8320 dnl
8321 dnl     $1 = condition to pass to "test"
8322 dnl     $2 = environment variable
8323 dnl     $3 = value if the test succeeds
8324 dnl     $4 = value if the test fails
8325 AC_DEFUN([CF_SUBST_IF],
8326 [
8327 if test $1 ; then
8328         $2=$3
8329 ifelse($4,,,[else
8330         $2=$4])
8331 fi
8332 AC_SUBST($2)
8333 ])dnl
8334 dnl ---------------------------------------------------------------------------
8335 dnl CF_SUBST_NCURSES_VERSION version: 11 updated: 2023/01/07 16:32:06
8336 dnl ------------------------
8337 dnl Get the version-number for use in shared-library naming, etc.
8338 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
8339 [AC_REQUIRE([AC_PROG_EGREP])dnl
8340
8341 NCURSES_MAJOR="`${EGREP-egrep} '^NCURSES_MAJOR[[        ]]*=' "$srcdir/dist.mk" | sed -e 's/^[[^0-9]]*//'`"
8342 NCURSES_MINOR="`${EGREP-egrep} '^NCURSES_MINOR[[        ]]*=' "$srcdir/dist.mk" | sed -e 's/^[[^0-9]]*//'`"
8343 NCURSES_PATCH="`${EGREP-egrep} '^NCURSES_PATCH[[        ]]*=' "$srcdir/dist.mk" | sed -e 's/^[[^0-9]]*//'`"
8344 cf_cv_abi_version=${NCURSES_MAJOR}
8345 cf_cv_abi_default=${NCURSES_MAJOR}
8346 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
8347 dnl Show the computed version, for logging
8348 cf_cv_timestamp=`date`
8349 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_default ($cf_cv_timestamp))
8350 dnl We need these values in the generated headers
8351 AC_SUBST(NCURSES_MAJOR)
8352 AC_SUBST(NCURSES_MINOR)
8353 AC_SUBST(NCURSES_PATCH)
8354 dnl We need these values in the generated makefiles
8355 AC_SUBST(cf_cv_rel_version)
8356 AC_SUBST(cf_cv_abi_version)
8357 AC_SUBST(cf_cv_abi_default)
8358 AC_SUBST(cf_cv_builtin_bool)
8359 AC_SUBST(cf_cv_header_stdbool_h)
8360 AC_SUBST(cf_cv_type_of_bool)dnl
8361 ])dnl
8362 dnl ---------------------------------------------------------------------------
8363 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
8364 dnl ------------------
8365 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
8366 dnl older SCO configurations.
8367 AC_DEFUN([CF_SYS_TIME_SELECT],
8368 [
8369 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
8370 AC_CACHE_VAL(cf_cv_sys_time_select,[
8371 AC_TRY_COMPILE([
8372 #include <sys/types.h>
8373 #ifdef HAVE_SYS_TIME_H
8374 #include <sys/time.h>
8375 #endif
8376 #ifdef HAVE_SYS_SELECT_H
8377 #include <sys/select.h>
8378 #endif
8379 ],[],[cf_cv_sys_time_select=yes],
8380          [cf_cv_sys_time_select=no])
8381          ])
8382 AC_MSG_RESULT($cf_cv_sys_time_select)
8383 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
8384 ])dnl
8385 dnl ---------------------------------------------------------------------------
8386 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
8387 dnl ---------------
8388 dnl Define a top_builddir symbol, for applications that need an absolute path.
8389 AC_DEFUN([CF_TOP_BUILDDIR],
8390 [
8391 top_builddir=ifelse($1,,`pwd`,$1)
8392 AC_SUBST(top_builddir)
8393 ])dnl
8394 dnl ---------------------------------------------------------------------------
8395 dnl CF_TRY_PKG_CONFIG version: 6 updated: 2020/12/31 10:54:15
8396 dnl -----------------
8397 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
8398 dnl available in that form.
8399 dnl
8400 dnl $1 = package name, which may be a shell variable
8401 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
8402 dnl $3 = logic to use if pkg-config does not have the package
8403 AC_DEFUN([CF_TRY_PKG_CONFIG],[
8404 AC_REQUIRE([CF_PKG_CONFIG])
8405
8406 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists "$1"; then
8407         CF_VERBOSE(found package $1)
8408         cf_pkgconfig_incs="`$PKG_CONFIG --cflags "$1" 2>/dev/null`"
8409         cf_pkgconfig_libs="`$PKG_CONFIG --libs   "$1" 2>/dev/null`"
8410         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
8411         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
8412         CF_ADD_CFLAGS($cf_pkgconfig_incs)
8413         CF_ADD_LIBS($cf_pkgconfig_libs)
8414         ifelse([$2],,:,[$2])
8415 else
8416         cf_pkgconfig_incs=
8417         cf_pkgconfig_libs=
8418         ifelse([$3],,:,[$3])
8419 fi
8420 ])
8421 dnl ---------------------------------------------------------------------------
8422 dnl CF_TRY_XOPEN_SOURCE version: 4 updated: 2022/09/10 15:16:16
8423 dnl -------------------
8424 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
8425 dnl can define it successfully.
8426 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
8427 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
8428         AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,
8429         [cf_cv_xopen_source=no],
8430         [cf_save="$CPPFLAGS"
8431          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
8432          AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,
8433                 [cf_cv_xopen_source=no],
8434                 [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
8435                 CPPFLAGS="$cf_save"
8436         ])
8437 ])
8438
8439 if test "$cf_cv_xopen_source" != no ; then
8440         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
8441         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
8442         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
8443         CF_APPEND_CFLAGS($cf_temp_xopen_source)
8444 fi
8445 ])
8446 dnl ---------------------------------------------------------------------------
8447 dnl CF_TYPEOF_CHTYPE version: 11 updated: 2023/01/05 17:57:59
8448 dnl ----------------
8449 dnl Determine the type we should use for chtype (and attr_t, which is treated
8450 dnl as the same thing).  We want around 32 bits, so on most machines want a
8451 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
8452 dnl wide characters, we have to have a type compatible with that, as well.
8453 AC_DEFUN([CF_TYPEOF_CHTYPE],
8454 [
8455 AC_MSG_CHECKING([for type of chtype])
8456 AC_CACHE_VAL(cf_cv_typeof_chtype,[
8457                 AC_TRY_RUN([
8458 $ac_includes_default
8459 #define WANT_BITS 31
8460 int main(void)
8461 {
8462         FILE *fp = fopen("cf_test.out", "w");
8463         if (fp != 0) {
8464                 char *result = "long";
8465                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
8466                         int n;
8467                         unsigned int x, y;
8468                         for (n = 0; n < WANT_BITS; n++) {
8469                                 x = (1 << n);
8470                                 y = (x >> n);
8471                                 if (y != 1 || x == 0) {
8472                                         x = 0;
8473                                         break;
8474                                 }
8475                         }
8476                         /*
8477                          * If x is nonzero, an int is big enough for the bits
8478                          * that we want.
8479                          */
8480                         result = (x != 0) ? "int" : "long";
8481                 }
8482                 fputs(result, fp);
8483                 fclose(fp);
8484         }
8485         ${cf_cv_main_return:-return}(0);
8486 }
8487                 ],
8488                 [cf_cv_typeof_chtype=`cat cf_test.out`],
8489                 [cf_cv_typeof_chtype=long],
8490                 [cf_cv_typeof_chtype=long])
8491                 rm -f cf_test.out
8492         ])
8493 AC_MSG_RESULT($cf_cv_typeof_chtype)
8494
8495 AC_SUBST(cf_cv_typeof_chtype)
8496 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
8497 ])dnl
8498 dnl ---------------------------------------------------------------------------
8499 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
8500 dnl -----------------
8501 dnl
8502 AC_DEFUN([CF_TYPE_SIGACTION],
8503 [
8504 AC_MSG_CHECKING([for type sigaction_t])
8505 AC_CACHE_VAL(cf_cv_type_sigaction,[
8506         AC_TRY_COMPILE([
8507 #include <signal.h>],
8508                 [sigaction_t x],
8509                 [cf_cv_type_sigaction=yes],
8510                 [cf_cv_type_sigaction=no])])
8511 AC_MSG_RESULT($cf_cv_type_sigaction)
8512 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
8513 ])dnl
8514 dnl ---------------------------------------------------------------------------
8515 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
8516 dnl --------------------
8517 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
8518 dnl won't, but they're still there.
8519 AC_DEFUN([CF_UNSIGNED_LITERALS],
8520 [
8521 AC_MSG_CHECKING([if unsigned literals are legal])
8522 AC_CACHE_VAL(cf_cv_unsigned_literals,[
8523         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
8524                 [cf_cv_unsigned_literals=yes],
8525                 [cf_cv_unsigned_literals=no])
8526         ])
8527 AC_MSG_RESULT($cf_cv_unsigned_literals)
8528 ])dnl
8529 dnl ---------------------------------------------------------------------------
8530 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
8531 dnl --------
8532 dnl Make an uppercase version of a variable
8533 dnl $1=uppercase($2)
8534 AC_DEFUN([CF_UPPER],
8535 [
8536 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
8537 ])dnl
8538 dnl ---------------------------------------------------------------------------
8539 dnl CF_UTF8_LIB version: 10 updated: 2023/01/11 04:05:23
8540 dnl -----------
8541 dnl Check for multibyte support, and if not found, utf8 compatibility library
8542 AC_DEFUN([CF_UTF8_LIB],
8543 [
8544 AC_HAVE_HEADERS(wchar.h)
8545 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
8546         cf_save_LIBS="$LIBS"
8547         AC_TRY_LINK([
8548 $ac_includes_default
8549 #ifdef HAVE_WCHAR_H
8550 #include <wchar.h>
8551 #endif
8552 ],[putwc(0,0);],
8553         [cf_cv_utf8_lib=yes],
8554         [CF_FIND_LINKAGE([
8555 #include <libutf8.h>],[putwc(0,0);],utf8,
8556                 [cf_cv_utf8_lib=add-on],
8557                 [cf_cv_utf8_lib=no])
8558 ])])
8559
8560 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
8561 # ncurses/ncursesw:
8562 if test "$cf_cv_utf8_lib" = "add-on" ; then
8563         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
8564         CF_ADD_INCDIR($cf_cv_header_path_utf8)
8565         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
8566         CF_ADD_LIBS($cf_cv_library_file_utf8)
8567 fi
8568 ])dnl
8569 dnl ---------------------------------------------------------------------------
8570 dnl CF_VA_COPY version: 6 updated: 2018/12/04 18:14:25
8571 dnl ----------
8572 dnl check for va_copy, part of stdarg.h starting with ISO C 1999.
8573 dnl Also, workaround for glibc's __va_copy, by checking for both.
8574 dnl Finally, try to accommodate pre-ISO C 1999 headers.
8575 AC_DEFUN([CF_VA_COPY],[
8576 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
8577 AC_TRY_LINK([
8578 #include <stdarg.h>
8579 ],[
8580         static va_list dst;
8581         static va_list src;
8582         va_copy(dst, src)],
8583         cf_cv_have_va_copy=yes,
8584         cf_cv_have_va_copy=no)])
8585
8586 if test "$cf_cv_have_va_copy" = yes;
8587 then
8588         AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
8589 else # !cf_cv_have_va_copy
8590
8591 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
8592 AC_TRY_LINK([
8593 #include <stdarg.h>
8594 ],[
8595         static va_list dst;
8596         static va_list src;
8597         __va_copy(dst, src)],
8598         cf_cv_have___va_copy=yes,
8599         cf_cv_have___va_copy=no)])
8600
8601 if test "$cf_cv_have___va_copy" = yes
8602 then
8603         AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
8604 else # !cf_cv_have___va_copy
8605
8606 AC_CACHE_CHECK(for __builtin_va_copy, cf_cv_have___builtin_va_copy,[
8607 AC_TRY_LINK([
8608 #include <stdarg.h>
8609 ],[
8610         static va_list dst;
8611         static va_list src;
8612         __builtin_va_copy(dst, src)],
8613         cf_cv_have___builtin_va_copy=yes,
8614         cf_cv_have___builtin_va_copy=no)])
8615
8616 test "$cf_cv_have___builtin_va_copy" = yes &&
8617         AC_DEFINE(HAVE___BUILTIN_VA_COPY,1,[Define to 1 if we have __builtin_va_copy])
8618
8619 fi # cf_cv_have___va_copy
8620
8621 fi # cf_cv_have_va_copy
8622
8623 case "${cf_cv_have_va_copy}${cf_cv_have___va_copy}${cf_cv_have___builtin_va_copy}" in
8624 (*yes*)
8625         ;;
8626
8627 (*)
8628         AC_CACHE_CHECK(if we can simply copy va_list, cf_cv_pointer_va_list,[
8629 AC_TRY_LINK([
8630 #include <stdarg.h>
8631 ],[
8632         va_list dst;
8633         va_list src;
8634         dst = src],
8635         cf_cv_pointer_va_list=yes,
8636         cf_cv_pointer_va_list=no)])
8637
8638         if test "$cf_cv_pointer_va_list" = no
8639         then
8640                 AC_CACHE_CHECK(if we can copy va_list indirectly, cf_cv_array_va_list,[
8641 AC_TRY_LINK([
8642 #include <stdarg.h>
8643 ],[
8644         va_list dst;
8645         va_list src;
8646         *dst = *src],
8647                         cf_cv_array_va_list=yes,
8648                         cf_cv_array_va_list=no)])
8649                 test "$cf_cv_array_va_list" = yes && AC_DEFINE(ARRAY_VA_LIST,1,[Define to 1 if we can copy va_list indirectly])
8650         fi
8651         ;;
8652 esac
8653 ])
8654 dnl ---------------------------------------------------------------------------
8655 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
8656 dnl ----------
8657 dnl Use AC_VERBOSE w/o the warnings
8658 AC_DEFUN([CF_VERBOSE],
8659 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
8660 CF_MSG_LOG([$1])
8661 ])dnl
8662 dnl ---------------------------------------------------------------------------
8663 dnl CF_VERSION_INFO version: 8 updated: 2021/01/01 13:31:04
8664 dnl ---------------
8665 dnl Define several useful symbols derived from the VERSION file.  A separate
8666 dnl file is preferred to embedding the version numbers in various scripts.
8667 dnl (automake is a textbook-example of why the latter is a bad idea, but there
8668 dnl are others).
8669 dnl
8670 dnl The file contents are:
8671 dnl     libtool-version release-version patch-version
8672 dnl or
8673 dnl     release-version
8674 dnl where
8675 dnl     libtool-version (see ?) consists of 3 integers separated by '.'
8676 dnl     release-version consists of a major version and minor version
8677 dnl             separated by '.', optionally followed by a patch-version
8678 dnl             separated by '-'.  The minor version need not be an
8679 dnl             integer (but it is preferred).
8680 dnl     patch-version is an integer in the form yyyymmdd, so ifdef's and
8681 dnl             scripts can easily compare versions.
8682 dnl
8683 dnl If libtool is used, the first form is required, since CF_WITH_LIBTOOL
8684 dnl simply extracts the first field using 'cut -f1'.
8685 dnl
8686 dnl Optional parameters:
8687 dnl $1 = internal name for package
8688 dnl $2 = external name for package
8689 AC_DEFUN([CF_VERSION_INFO],
8690 [
8691 if test -f "$srcdir/VERSION" ; then
8692         AC_MSG_CHECKING(for package version)
8693
8694         # if there are not enough fields, cut returns the last one...
8695         cf_field1=`sed -e '2,$d' "$srcdir/VERSION" |cut -f1`
8696         cf_field2=`sed -e '2,$d' "$srcdir/VERSION" |cut -f2`
8697         cf_field3=`sed -e '2,$d' "$srcdir/VERSION" |cut -f3`
8698
8699         # this is how CF_BUNDLED_INTL uses $VERSION:
8700         VERSION="$cf_field1"
8701
8702         VERSION_MAJOR=`echo "$cf_field2" | sed -e 's/\..*//'`
8703         test -z "$VERSION_MAJOR" && AC_MSG_ERROR(missing major-version)
8704
8705         VERSION_MINOR=`echo "$cf_field2" | sed -e 's/^[[^.]]*\.//' -e 's/-.*//'`
8706         test -z "$VERSION_MINOR" && AC_MSG_ERROR(missing minor-version)
8707
8708         AC_MSG_RESULT(${VERSION_MAJOR}.${VERSION_MINOR})
8709
8710         AC_MSG_CHECKING(for package patch date)
8711         VERSION_PATCH=`echo "$cf_field3" | sed -e 's/^[[^-]]*-//'`
8712         case .$VERSION_PATCH in
8713         (.)
8714                 AC_MSG_ERROR(missing patch-date $VERSION_PATCH)
8715                 ;;
8716         (.[[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]])
8717                 ;;
8718         (*)
8719                 AC_MSG_ERROR(illegal patch-date $VERSION_PATCH)
8720                 ;;
8721         esac
8722         AC_MSG_RESULT($VERSION_PATCH)
8723 else
8724         AC_MSG_ERROR(did not find $srcdir/VERSION)
8725 fi
8726
8727 # show the actual data that we have for versions:
8728 CF_VERBOSE(ABI VERSION $VERSION)
8729 CF_VERBOSE(VERSION_MAJOR $VERSION_MAJOR)
8730 CF_VERBOSE(VERSION_MINOR $VERSION_MINOR)
8731 CF_VERBOSE(VERSION_PATCH $VERSION_PATCH)
8732
8733 AC_SUBST(VERSION)
8734 AC_SUBST(VERSION_MAJOR)
8735 AC_SUBST(VERSION_MINOR)
8736 AC_SUBST(VERSION_PATCH)
8737
8738 dnl if a package name is given, define its corresponding version info.  We
8739 dnl need the package name to ensure that the defined symbols are unique.
8740 ifelse($1,,,[
8741         cf_PACKAGE=$1
8742         PACKAGE=ifelse($2,,$1,$2)
8743         AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",[Define to the package-name])
8744         AC_SUBST(PACKAGE)
8745         CF_UPPER(cf_PACKAGE,$cf_PACKAGE)
8746         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_VERSION,"${VERSION_MAJOR}.${VERSION_MINOR}")
8747         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_PATCHDATE,${VERSION_PATCH})
8748 ])
8749 ])dnl
8750 dnl ---------------------------------------------------------------------------
8751 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
8752 dnl -------------
8753 dnl Check if type wide-character type $1 is declared, and if so, which header
8754 dnl file is needed.  The second parameter is used to set a shell variable when
8755 dnl the type is not found.  The first parameter sets a shell variable for the
8756 dnl opposite sense.
8757 AC_DEFUN([CF_WCHAR_TYPE],
8758 [
8759 # This is needed on Tru64 5.0 to declare $1
8760 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
8761 AC_TRY_COMPILE([
8762 #include <stdlib.h>
8763 #include <stdarg.h>
8764 #include <stdio.h>
8765 #ifdef HAVE_LIBUTF8_H
8766 #include <libutf8.h>
8767 #endif],
8768         [$1 state],
8769         [cf_cv_$1=no],
8770         [AC_TRY_COMPILE([
8771 #include <stdlib.h>
8772 #include <stdarg.h>
8773 #include <stdio.h>
8774 #include <wchar.h>
8775 #ifdef HAVE_LIBUTF8_H
8776 #include <libutf8.h>
8777 #endif],
8778         [$1 value],
8779         [cf_cv_$1=yes],
8780         [cf_cv_$1=unknown])])])
8781
8782 if test "$cf_cv_$1" = yes ; then
8783         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
8784         NEED_WCHAR_H=1
8785 fi
8786
8787 ifelse([$2],,,[
8788 # if we do not find $1 in either place, use substitution to provide a fallback.
8789 if test "$cf_cv_$1" = unknown ; then
8790         $2=1
8791 fi
8792 ])
8793 ifelse($3,,,[
8794 # if we find $1 in either place, use substitution to provide a fallback.
8795 if test "$cf_cv_$1" != unknown ; then
8796         $3=1
8797 fi
8798 ])
8799 ])dnl
8800 dnl ---------------------------------------------------------------------------
8801 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
8802 dnl ---------------
8803 dnl Check for compiler-support for weak symbols.
8804 dnl This works with "recent" gcc.
8805 AC_DEFUN([CF_WEAK_SYMBOLS],[
8806 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
8807
8808 AC_TRY_COMPILE([
8809 #include <stdio.h>],
8810 [
8811 #if defined(__GNUC__)
8812 #  if defined __USE_ISOC99
8813 #    define _cat_pragma(exp)    _Pragma(#exp)
8814 #    define _weak_pragma(exp)   _cat_pragma(weak name)
8815 #  else
8816 #    define _weak_pragma(exp)
8817 #  endif
8818 #  define _declare(name)        __extension__ extern __typeof__(name) name
8819 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
8820 #endif
8821
8822 weak_symbol(fopen);
8823 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
8824 ])
8825 ])dnl
8826 dnl ---------------------------------------------------------------------------
8827 dnl CF_WITH_ABI_ALTERED version: 1 updated: 2023/01/07 16:32:06
8828 dnl -------------------
8829 dnl Provide a way to override the displayed ABI version, e.g., in filenames.
8830 dnl Check this option after using the ABI version in configuration decisions.
8831 AC_DEFUN([CF_WITH_ABI_ALTERED],[
8832 AC_REQUIRE([CF_WITH_ABI_VERSION])
8833 AC_REQUIRE([CF_ABI_DEFAULTS])
8834 AC_ARG_WITH(abi-altered,
8835 [  --with-abi-altered=XXX  override visible ABI version, for packaging],[
8836         CF_NUMBER_SYNTAX($withval,ABI altered)
8837         if test "$cf_cv_abi_version" != "$withval"
8838         then
8839                 AC_MSG_WARN(altering visible ABI from $cf_cv_abi_version to $withval)
8840                 cf_cv_abi_version=$withval
8841         fi
8842 ])dnl
8843 ])dnl
8844 dnl ---------------------------------------------------------------------------
8845 dnl CF_WITH_ABI_VERSION version: 5 updated: 2023/01/07 16:32:06
8846 dnl -------------------
8847 dnl Allow library's ABI to be overridden.  Generally this happens when a
8848 dnl packager has incremented the ABI past that used in the original package,
8849 dnl and wishes to keep doing this.
8850 dnl
8851 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
8852 dnl symbol.
8853 AC_DEFUN([CF_WITH_ABI_VERSION],[
8854 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
8855 AC_ARG_WITH(abi-version,
8856 [  --with-abi-version=XXX  override derived ABI version],[
8857         if test "x$cf_cv_abi_version" != "x$withval"
8858         then
8859                 AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
8860                 case "$cf_cv_rel_version" in
8861                 (5.*)
8862                         cf_cv_rel_version=$withval.0
8863                         ;;
8864                 (6.*)
8865                         cf_cv_rel_version=$withval.9    # FIXME: should be 10 as of 6.0 release
8866                         ;;
8867                 esac
8868         fi
8869         cf_cv_abi_version=$withval])
8870         CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
8871 ifelse($1,,,[
8872 $1_ABI=$cf_cv_abi_version
8873 ])
8874 cf_cv_abi_default=$cf_cv_abi_version
8875 ])dnl
8876 dnl ---------------------------------------------------------------------------
8877 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
8878 dnl --------------------
8879 dnl Command-line option to specify the Ada95 compiler.
8880 AC_DEFUN([CF_WITH_ADA_COMPILER],[
8881 AC_MSG_CHECKING(for ada-compiler)
8882 AC_ARG_WITH(ada-compiler,
8883         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
8884         [cf_ada_compiler=$withval],
8885         [cf_ada_compiler=gnatmake])
8886 AC_SUBST(cf_ada_compiler)
8887 AC_MSG_RESULT($cf_ada_compiler)
8888 ])dnl
8889 dnl ---------------------------------------------------------------------------
8890 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
8891 dnl -------------------
8892 dnl Command-line option to specify where Ada includes will install.
8893 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
8894 AC_MSG_CHECKING(for ada-include)
8895 CF_WITH_PATH(ada-include,
8896    [  --with-ada-include=DIR  Ada includes are in DIR],
8897    ADA_INCLUDE,
8898    PREFIX/share/ada/adainclude,
8899    [$]prefix/share/ada/adainclude)
8900 AC_SUBST(ADA_INCLUDE)
8901 AC_MSG_RESULT($ADA_INCLUDE)
8902 ])dnl
8903 dnl ---------------------------------------------------------------------------
8904 dnl CF_WITH_ADA_LIBNAME version: 1 updated: 2019/09/07 18:59:41
8905 dnl -------------------
8906 dnl CF_WITH_ADA_LIBNAME
8907 dnl -------------------
8908 dnl Command-line option to specify how to name the resulting Ada library.
8909 dnl $1 = default value
8910 AC_DEFUN([CF_WITH_ADA_LIBNAME],[
8911 AC_MSG_CHECKING(for ada-libname)
8912 AC_ARG_WITH(ada-libname,
8913    [  --with-ada-libname=XXX  override default Ada library-name],
8914    ADA_LIBNAME=[$]withval,
8915    ADA_LIBNAME=$1)
8916 case "x$ADA_LIBNAME" in
8917 (x|xyes|xno)
8918         ADA_LIBNAME=$1
8919         ;;
8920 esac
8921 AC_SUBST(ADA_LIBNAME)
8922 AC_MSG_RESULT($ADA_LIBNAME)
8923 ])dnl
8924 dnl ---------------------------------------------------------------------------
8925 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
8926 dnl -------------------
8927 dnl Command-line option to specify where Ada objects will install.
8928 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
8929 AC_MSG_CHECKING(for ada-objects)
8930 CF_WITH_PATH(ada-objects,
8931    [  --with-ada-objects=DIR  Ada objects are in DIR],
8932    ADA_OBJECTS,
8933    PREFIX/lib/ada/adalib,
8934    [$]prefix/lib/ada/adalib)
8935 AC_SUBST(ADA_OBJECTS)
8936 AC_MSG_RESULT($ADA_OBJECTS)
8937 ])dnl
8938 dnl ---------------------------------------------------------------------------
8939 dnl CF_WITH_ADA_SHAREDLIB version: 5 updated: 2018/07/21 19:10:35
8940 dnl ---------------------
8941 dnl Command-line option to specify if an Ada95 shared-library should be built,
8942 dnl and optionally what its soname should be.
8943 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
8944 AC_REQUIRE([CF_GNAT_PROJECTS])
8945 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
8946 AC_ARG_WITH(ada-sharedlib,
8947         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
8948         [with_ada_sharedlib=$withval],
8949         [with_ada_sharedlib=no])
8950 AC_MSG_RESULT($with_ada_sharedlib)
8951
8952 if test "x$with_ada_sharedlib" != xno
8953 then
8954         if test "x$cf_gnat_projects" != xyes
8955         then
8956                 AC_MSG_WARN(disabling shared-library since GNAT projects are not supported)
8957                 with_ada_sharedlib=no
8958         fi
8959 fi
8960
8961 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
8962 MAKE_ADA_SHAREDLIB="#"
8963
8964 if test "x$with_ada_sharedlib" != xno
8965 then
8966         MAKE_ADA_SHAREDLIB=
8967         if test "x$with_ada_sharedlib" != xyes
8968         then
8969                 ADA_SHAREDLIB="$with_ada_sharedlib"
8970         fi
8971 fi
8972
8973 AC_SUBST(ADA_SHAREDLIB)
8974 AC_SUBST(MAKE_ADA_SHAREDLIB)
8975 ])dnl
8976 dnl ---------------------------------------------------------------------------
8977 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
8978 dnl ----------------
8979 dnl Configure-option for dbmalloc.  The optional parameter is used to override
8980 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
8981 AC_DEFUN([CF_WITH_DBMALLOC],[
8982 CF_NO_LEAKS_OPTION(dbmalloc,
8983         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
8984         [USE_DBMALLOC])
8985
8986 if test "$with_dbmalloc" = yes ; then
8987         AC_CHECK_HEADER(dbmalloc.h,
8988                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
8989 fi
8990 ])dnl
8991 dnl ---------------------------------------------------------------------------
8992 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
8993 dnl ---------------
8994 dnl Configure-option for dmalloc.  The optional parameter is used to override
8995 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
8996 AC_DEFUN([CF_WITH_DMALLOC],[
8997 CF_NO_LEAKS_OPTION(dmalloc,
8998         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
8999         [USE_DMALLOC])
9000
9001 if test "$with_dmalloc" = yes ; then
9002         AC_CHECK_HEADER(dmalloc.h,
9003                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
9004 fi
9005 ])dnl
9006 dnl ---------------------------------------------------------------------------
9007 dnl CF_WITH_EXPORT_SYMS version: 3 updated: 2014/12/20 19:16:08
9008 dnl -------------------
9009 dnl Use this with libtool to specify the list of symbols that may be exported.
9010 dnl The input file contains one symbol per line; comments work with "#".
9011 dnl
9012 dnl $1 = basename of the ".sym" file (default $PACKAGE)
9013 AC_DEFUN([CF_WITH_EXPORT_SYMS],
9014 [
9015 AC_MSG_CHECKING(if exported-symbols file should be used)
9016 AC_ARG_WITH(export-syms,
9017         [  --with-export-syms=XXX  limit exported symbols using libtool],
9018         [with_export_syms=$withval],
9019         [with_export_syms=no])
9020 if test "x$with_export_syms" = xyes
9021 then
9022         with_export_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).sym'
9023         AC_SUBST(PACKAGE)
9024 fi
9025 AC_MSG_RESULT($with_export_syms)
9026 if test "x$with_export_syms" != xno
9027 then
9028         EXPORT_SYMS="-export-symbols $with_export_syms"
9029         AC_SUBST(EXPORT_SYMS)
9030 fi
9031 ])dnl
9032 dnl ---------------------------------------------------------------------------
9033 dnl CF_WITH_GPM version: 10 updated: 2017/04/29 18:32:18
9034 dnl -----------
9035 dnl
9036 dnl The option parameter (if neither yes/no) is assumed to be the name of
9037 dnl the gpm library, e.g., for dynamic loading.
9038 AC_DEFUN([CF_WITH_GPM],
9039 [
9040 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
9041 AC_ARG_WITH(gpm,
9042         [  --with-gpm              use Alessandro Rubini's GPM library],
9043         [with_gpm=$withval],
9044         [with_gpm=maybe])
9045 AC_MSG_RESULT($with_gpm)
9046
9047 if test "$with_gpm" != no ; then
9048         AC_CHECK_HEADER(gpm.h,[
9049                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
9050                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
9051                         CF_VERBOSE(assuming we really have GPM library)
9052                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
9053                         with_gpm=yes
9054                 else
9055                         AC_CHECK_LIB(gpm,Gpm_Open,[with_gpm=yes],[
9056                                 if test "$with_gpm" = maybe; then
9057                                         AC_MSG_WARN(Cannot link with GPM library)
9058                                         with_gpm=no
9059                                 else
9060                                         AC_MSG_ERROR(Cannot link with GPM library)
9061                                 fi
9062                         ])
9063                 fi
9064         ],[
9065                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
9066                 with_gpm=no
9067         ])
9068 fi
9069 ])
9070 dnl ---------------------------------------------------------------------------
9071 dnl CF_WITH_LIBTOOL version: 36 updated: 2021/01/01 13:31:04
9072 dnl ---------------
9073 dnl Provide a configure option to incorporate libtool.  Define several useful
9074 dnl symbols for the makefile rules.
9075 dnl
9076 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
9077 dnl macros from libtool.m4 which is in the aclocal directory of automake.
9078 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
9079 dnl But that still does not work properly since the macro is expanded outside
9080 dnl the CF_WITH_LIBTOOL macro:
9081 dnl
9082 dnl     #!/bin/sh
9083 dnl     ACLOCAL=`aclocal --print-ac-dir`
9084 dnl     if test -z "$ACLOCAL" ; then
9085 dnl             echo cannot find aclocal directory
9086 dnl             exit 1
9087 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
9088 dnl             echo cannot find libtool.m4 file
9089 dnl             exit 1
9090 dnl     fi
9091 dnl
9092 dnl     LOCAL=aclocal.m4
9093 dnl     ORIG=aclocal.m4.orig
9094 dnl
9095 dnl     trap "mv $ORIG $LOCAL" 0 1 2 3 15
9096 dnl     rm -f $ORIG
9097 dnl     mv $LOCAL $ORIG
9098 dnl
9099 dnl     # sed the LIBTOOL= assignment to omit the current directory?
9100 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
9101 dnl     cat $ORIG >>$LOCAL
9102 dnl
9103 dnl     autoconf-257 $*
9104 dnl
9105 AC_DEFUN([CF_WITH_LIBTOOL],
9106 [
9107 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
9108 ifdef([AC_PROG_LIBTOOL],,[
9109 LIBTOOL=
9110 ])
9111 # common library maintenance symbols that are convenient for libtool scripts:
9112 LIB_CREATE='${AR} -cr'
9113 LIB_OBJECT='${OBJECTS}'
9114 LIB_SUFFIX=.a
9115 LIB_PREP="$RANLIB"
9116
9117 # symbols used to prop libtool up to enable it to determine what it should be
9118 # doing:
9119 LIB_CLEAN=
9120 LIB_COMPILE=
9121 LIB_LINK='${CC}'
9122 LIB_INSTALL=
9123 LIB_UNINSTALL=
9124
9125 AC_MSG_CHECKING(if you want to build libraries with libtool)
9126 AC_ARG_WITH(libtool,
9127         [  --with-libtool          generate libraries with libtool],
9128         [with_libtool=$withval],
9129         [with_libtool=no])
9130 AC_MSG_RESULT($with_libtool)
9131 if test "$with_libtool" != "no"; then
9132 ifdef([AC_PROG_LIBTOOL],[
9133         # missing_content_AC_PROG_LIBTOOL{{
9134         AC_PROG_LIBTOOL
9135         # missing_content_AC_PROG_LIBTOOL}}
9136 ],[
9137         if test "$with_libtool" != "yes" ; then
9138                 CF_PATH_SYNTAX(with_libtool)
9139                 LIBTOOL=$with_libtool
9140         else
9141                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
9142                 CF_LIBTOOL_VERSION
9143                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
9144                 then
9145                         CF_FORGET_TOOL(LIBTOOL)
9146                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
9147                         CF_LIBTOOL_VERSION
9148                 fi
9149         fi
9150         if test -z "$LIBTOOL" ; then
9151                 AC_MSG_ERROR(Cannot find libtool)
9152         fi
9153 ])dnl
9154         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${libdir} ${LIBTOOL_VERSION} `cut -f1 ${top_srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
9155         LIB_OBJECT='${OBJECTS:.o=.lo}'
9156         LIB_SUFFIX=.la
9157         LIB_CLEAN='${LIBTOOL} --mode=clean'
9158         LIB_COMPILE='${LIBTOOL} --mode=compile'
9159         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
9160         LIB_INSTALL='${LIBTOOL} --mode=install'
9161         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
9162         LIB_PREP=:
9163
9164         CF_CHECK_LIBTOOL_VERSION
9165
9166         # special hack to add -no-undefined (which libtool should do for itself)
9167         LT_UNDEF=
9168         case "$cf_cv_system_name" in
9169         (cygwin*|msys*|mingw32*|os2*|uwin*|aix[[4-7]])
9170                 LT_UNDEF=-no-undefined
9171                 ;;
9172         esac
9173         AC_SUBST([LT_UNDEF])
9174
9175         # special hack to add --tag option for C++ compiler
9176         case "$cf_cv_libtool_version" in
9177         (1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*)
9178                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
9179                 LIBTOOL="$LIBTOOL --tag=CC"
9180                 ;;
9181         (*)
9182                 LIBTOOL_CXX="$LIBTOOL"
9183                 ;;
9184         esac
9185 else
9186         LIBTOOL=""
9187         LIBTOOL_CXX=""
9188 fi
9189
9190 test -z "$LIBTOOL" && ECHO_LT=
9191
9192 AC_SUBST(LIBTOOL)
9193 AC_SUBST(LIBTOOL_CXX)
9194 AC_SUBST(LIBTOOL_OPTS)
9195
9196 AC_SUBST(LIB_CREATE)
9197 AC_SUBST(LIB_OBJECT)
9198 AC_SUBST(LIB_SUFFIX)
9199 AC_SUBST(LIB_PREP)
9200
9201 AC_SUBST(LIB_CLEAN)
9202 AC_SUBST(LIB_COMPILE)
9203 AC_SUBST(LIB_LINK)
9204 AC_SUBST(LIB_INSTALL)
9205 AC_SUBST(LIB_UNINSTALL)
9206
9207 ])dnl
9208 dnl ---------------------------------------------------------------------------
9209 dnl CF_WITH_LIBTOOL_OPTS version: 4 updated: 2015/04/17 21:13:04
9210 dnl --------------------
9211 dnl Allow user to pass additional libtool options into the library creation
9212 dnl and link steps.  The main use for this is to do something like
9213 dnl     ./configure --with-libtool-opts=-static
9214 dnl to get the same behavior as automake-flavored
9215 dnl     ./configure --enable-static
9216 AC_DEFUN([CF_WITH_LIBTOOL_OPTS],[
9217 AC_MSG_CHECKING(for additional libtool options)
9218 AC_ARG_WITH(libtool-opts,
9219         [  --with-libtool-opts=XXX specify additional libtool options],
9220         [with_libtool_opts=$withval],
9221         [with_libtool_opts=no])
9222 AC_MSG_RESULT($with_libtool_opts)
9223
9224 case .$with_libtool_opts in
9225 (.yes|.no|.)
9226         ;;
9227 (*)
9228         LIBTOOL_OPTS="$LIBTOOL_OPTS $with_libtool_opts"
9229         ;;
9230 esac
9231
9232 AC_SUBST(LIBTOOL_OPTS)
9233 ])dnl
9234 dnl ---------------------------------------------------------------------------
9235 dnl CF_WITH_LIB_BASENAME version: 1 updated: 2020/03/07 20:05:14
9236 dnl --------------------
9237 dnl Allow for overriding the basename of a library, i.e., the part to which
9238 dnl prefixes/suffixes are attached.
9239 dnl
9240 dnl $1 = variable to set
9241 dnl $2 = option name
9242 dnl $3 = default basename for library, if omitted use $2
9243 AC_DEFUN([CF_WITH_LIB_BASENAME],
9244 [
9245 AC_MSG_CHECKING(for desired basename for $2 library)
9246 AC_ARG_WITH($2-libname,
9247         [  --with-$2-libname=XXX override ifelse($3,,$2,$3) basename of library],
9248         [with_lib_basename=$withval],
9249         [with_lib_basename=ifelse($3,,$2,$3)])
9250 $1="$with_lib_basename"
9251
9252 case "x[$]$1" in
9253 (x|xno|xnone|xyes)
9254         $1=ifelse($3,,$2,$3)
9255         ;;
9256 (*)
9257         ;;
9258 esac
9259
9260 AC_MSG_RESULT([$]$1)
9261 AC_SUBST($1)
9262 ])dnl
9263 dnl ---------------------------------------------------------------------------
9264 dnl CF_WITH_LIB_PREFIX version: 2 updated: 2021/01/01 16:53:59
9265 dnl ------------------
9266 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
9267 dnl "lib" prefix, e.g., because it used the dll naming convention.
9268 dnl
9269 dnl $1 = variable to set
9270 AC_DEFUN([CF_WITH_LIB_PREFIX],
9271 [
9272 AC_MSG_CHECKING(if you want to have a library-prefix)
9273 AC_ARG_WITH(lib-prefix,
9274         [  --with-lib-prefix       override library-prefix],
9275         [with_lib_prefix=$withval],
9276         [with_lib_prefix=auto])
9277 AC_MSG_RESULT($with_lib_prefix)
9278
9279 if test "$with_lib_prefix" = auto
9280 then
9281         CF_LIB_PREFIX($1)
9282 elif test "$with_lib_prefix" = no
9283 then
9284         LIB_PREFIX=
9285 else
9286         LIB_PREFIX=$with_lib_prefix
9287 fi
9288 ])dnl
9289 dnl ---------------------------------------------------------------------------
9290 dnl CF_WITH_PATH version: 12 updated: 2021/09/04 06:35:04
9291 dnl ------------
9292 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
9293 dnl defaulting to yes/no.
9294 dnl
9295 dnl $1 = option name
9296 dnl $2 = help-text
9297 dnl $3 = environment variable to set
9298 dnl $4 = default value, shown in the help-message, must be a constant
9299 dnl $5 = default value, if it is an expression & cannot be in the help-message
9300 dnl
9301 AC_DEFUN([CF_WITH_PATH],
9302 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
9303 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
9304 if ifelse([$5],,true,[test -n "$5"]) ; then
9305 CF_PATH_SYNTAX(withval)
9306 fi
9307 eval $3="$withval"
9308 AC_SUBST($3)dnl
9309 ])dnl
9310 dnl ---------------------------------------------------------------------------
9311 dnl CF_WITH_PATHLIST version: 13 updated: 2021/09/04 06:35:04
9312 dnl ----------------
9313 dnl Process an option specifying a list of colon-separated paths.
9314 dnl
9315 dnl $1 = option name
9316 dnl $2 = help-text
9317 dnl $3 = environment variable to set
9318 dnl $4 = default value, shown in the help-message, must be a constant
9319 dnl $5 = default value, if it is an expression & cannot be in the help-message
9320 dnl $6 = flag to tell if we want to define or substitute
9321 dnl
9322 AC_DEFUN([CF_WITH_PATHLIST],[
9323 AC_REQUIRE([CF_PATHSEP])
9324 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
9325 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
9326
9327 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
9328 cf_dst_path=
9329 for cf_src_path in $withval
9330 do
9331   CF_PATH_SYNTAX(cf_src_path)
9332   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
9333   cf_dst_path="${cf_dst_path}${cf_src_path}"
9334 done
9335 IFS="$ac_save_ifs"
9336
9337 ifelse($6,define,[
9338 # Strip single quotes from the value, e.g., when it was supplied as a literal
9339 # for $4 or $5.
9340 case "$cf_dst_path" in
9341 (\'*)
9342   cf_dst_path="`echo "$cf_dst_path" |sed -e s/\'// -e s/\'\$//`"
9343   ;;
9344 esac
9345 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
9346 ])
9347
9348 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
9349 # so we have to check/work around.  We do prefer the result of "eval"...
9350 eval cf_dst_eval="$cf_dst_path"
9351 case "x$cf_dst_eval" in
9352 (xNONE*)
9353         $3=$cf_dst_path
9354         ;;
9355 (*)
9356         $3="$cf_dst_eval"
9357         ;;
9358 esac
9359 AC_SUBST($3)dnl
9360
9361 ])dnl
9362 dnl ---------------------------------------------------------------------------
9363 dnl CF_WITH_PATH_PROG version: 1 updated: 2019/06/30 19:44:43
9364 dnl -----------------
9365 dnl Check for a given program, like CF_PATH_PROG, but allow override using a
9366 dnl "--with-xxx" option.
9367 dnl
9368 dnl Parameters:
9369 dnl             $1 = environment variable to set/update
9370 dnl             $2 = program name
9371 dnl             $3 = help-text
9372 dnl             $4 = $PATH
9373 AC_DEFUN([CF_WITH_PATH_PROG],[
9374 AC_ARG_WITH($2-path,
9375         [  --with-$2-path=XXX     specify path of $2 ifelse($3,,,$3)],
9376         [AC_MSG_CHECKING(for $2 program ifelse($3,,,$3))
9377                 $1=$withval
9378                 AC_MSG_RESULT([$]$1)
9379                 CF_PATH_SYNTAX($1)
9380         ],
9381         [CF_PATH_PROG($1,$2,,ifelse($4,,,$4))
9382                 if test -z "[$]$1"
9383                 then
9384                         AC_MSG_WARN(no $2 program found ifelse($3,,,$3))
9385                 fi
9386         ])
9387 ])
9388 dnl ---------------------------------------------------------------------------
9389 dnl CF_WITH_PCRE2 version: 6 updated: 2021/08/11 20:35:34
9390 dnl -------------
9391 dnl Add PCRE2 (Perl-compatible regular expressions v2) to the build if it is
9392 dnl available and the user requests it.  Assume the application will otherwise
9393 dnl use the POSIX interface.
9394 dnl
9395 dnl TODO allow $withval to specify package location
9396 AC_DEFUN([CF_WITH_PCRE2],
9397 [
9398 AC_REQUIRE([CF_PKG_CONFIG])
9399
9400 AC_MSG_CHECKING(if you want to use PCRE2 for regular-expressions)
9401 AC_ARG_WITH(pcre2,
9402         [  --with-pcre2            use PCRE2 for regular-expressions])
9403 test -z "$with_pcre2" && with_pcre2=no
9404 AC_MSG_RESULT($with_pcre2)
9405
9406 if test "x$with_pcre2" != xno ; then
9407         cf_with_pcre2_ok=no
9408         for cf_with_pcre2 in libpcre2 libpcre2-posix libpcre
9409         do
9410                 CF_TRY_PKG_CONFIG($cf_with_pcre2,[cf_with_pcre2_ok=yes; break])
9411         done
9412         cf_with_pcre2_ok=yes || AC_MSG_ERROR(Cannot find PCRE2 library)
9413
9414         AC_DEFINE(HAVE_LIB_PCRE2,1,[Define to 1 if we can/should compile with the PCRE2 library])
9415
9416         # if pkgconfig gave no results, look for the libraries directly
9417         case "$LIBS" in
9418         (*pcre2-posix*|*pcreposix*)
9419                 ;;
9420         (*)
9421                 AC_CHECK_LIB(pcre2-posix,regcomp,[
9422                         CF_ADD_LIB(pcre2-posix)],
9423                         [AC_CHECK_LIB(pcreposix,regcomp,[
9424                          CF_ADD_LIB(pcreposix)
9425                         ],[AC_MSG_ERROR(Cannot find PCRE2 POSIX library)])])
9426                 ;;
9427         esac
9428
9429         # either way, check for the library header files
9430         AC_CHECK_HEADERS(pcre2posix.h pcreposix.h)
9431         AC_CHECK_FUNCS(PCRE2regcomp)
9432 fi
9433 ])dnl
9434 dnl ---------------------------------------------------------------------------
9435 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 20 updated: 2022/01/29 17:03:42
9436 dnl -------------------------
9437 dnl Allow the choice of the pkg-config library directory to be overridden.
9438 dnl
9439 dnl pkg-config uses a search-list built from these colon-separated lists of
9440 dnl directories:
9441 dnl a) $PKG_CONFIG_PATH (tested first, added if set)
9442 dnl b) $PKG_CONFIG_LIBDIR (tested second, added if set)
9443 dnl c) builtin-list (added if $PKG_CONFIG_LIBDIR is not set)
9444 dnl
9445 dnl pkgconf (used with some systems such as FreeBSD in place of pkg-config)
9446 dnl optionally ignores $PKG_CONFIG_LIBDIR.
9447 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
9448
9449 case "$PKG_CONFIG" in
9450 (no|none|yes)
9451         AC_MSG_CHECKING(for pkg-config library directory)
9452         ;;
9453 (*)
9454         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
9455         ;;
9456 esac
9457
9458 # if $PKG_CONFIG_LIBDIR is set, try to use that
9459 cf_search_path=`echo "$PKG_CONFIG_LIBDIR" | sed -e 's/:/ /g' -e 's,^[[  ]]*,,'`
9460
9461 # if the option is used, let that override.  otherwise default to "libdir"
9462 AC_ARG_WITH(pkg-config-libdir,
9463         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
9464         [cf_search_path=$withval],
9465         [test "x$PKG_CONFIG" != xnone && test -z "$cf_search_path" && cf_search_path=libdir])
9466
9467 case "x$cf_search_path" in
9468 (xlibdir)
9469         PKG_CONFIG_LIBDIR='${libdir}/pkgconfig'
9470         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
9471         cf_search_path=
9472         ;;
9473 (x)
9474         ;;
9475 (x/*\ *)
9476         PKG_CONFIG_LIBDIR=
9477         ;;
9478 (x/*)
9479         PKG_CONFIG_LIBDIR="$cf_search_path"
9480         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
9481         cf_search_path=
9482         ;;
9483 (xyes|xauto)
9484         AC_MSG_RESULT(auto)
9485         cf_search_path=
9486         # Look for the library directory using the same prefix as the executable
9487         AC_MSG_CHECKING(for search-list)
9488         if test "x$PKG_CONFIG" != xnone
9489         then
9490                 # works for pkg-config since version 0.24 (2009)
9491                 # works for pkgconf since version 0.8.3 (2012)
9492                 for cf_pkg_program in \
9493                         `echo "$PKG_CONFIG" | sed -e 's,^.*/,,'` \
9494                         pkg-config \
9495                         pkgconf
9496                 do
9497                         cf_search_path=`"$PKG_CONFIG" --variable=pc_path "$cf_pkg_program" 2>/dev/null | tr : ' '`
9498                         test -n "$cf_search_path" && break
9499                 done
9500
9501                 # works for pkg-config since import in 2005 of original 2001 HP code.
9502                 test -z "$cf_search_path" && \
9503                 cf_search_path=`
9504                 "$PKG_CONFIG" --debug --exists no-such-package 2>&1 | $AWK "\
9505 /^Scanning directory (#[1-9][0-9]* )?'.*'$/{ \
9506         sub(\"^[[^']]*'\",\"\"); \
9507         sub(\"'.*\",\"\"); \
9508         printf \" %s\", \\[$]0; } \
9509 { next; } \
9510 "`
9511         fi
9512
9513         AC_MSG_RESULT($cf_search_path)
9514         ;;
9515 (*)
9516         AC_MSG_ERROR(Unexpected option value: $cf_search_path)
9517         ;;
9518 esac
9519
9520 if test -n "$cf_search_path"
9521 then
9522         AC_MSG_CHECKING(for first directory)
9523         cf_pkg_config_path=none
9524         for cf_config in $cf_search_path
9525         do
9526                 if test -d "$cf_config"
9527                 then
9528                         cf_pkg_config_path=$cf_config
9529                         break
9530                 fi
9531         done
9532         AC_MSG_RESULT($cf_pkg_config_path)
9533
9534         if test "x$cf_pkg_config_path" != xnone ; then
9535                 # limit this to the first directory found
9536                 PKG_CONFIG_LIBDIR="$cf_pkg_config_path"
9537         fi
9538
9539         if test -z "$PKG_CONFIG_LIBDIR" && test -n "$cf_search_path"
9540         then
9541                 AC_MSG_CHECKING(for workaround)
9542                 if test "$prefix" = "NONE" ; then
9543                         cf_prefix="$ac_default_prefix"
9544                 else
9545                         cf_prefix="$prefix"
9546                 fi
9547                 eval cf_libdir=$libdir
9548                 cf_libdir=`echo "$cf_libdir" | sed -e "s,^NONE,$cf_prefix,"`
9549                 cf_backup=
9550                 for cf_config in $cf_search_path
9551                 do
9552                         case $cf_config in
9553                         $cf_libdir/pkgconfig)
9554                                 PKG_CONFIG_LIBDIR=$cf_libdir/pkgconfig
9555                                 break
9556                                 ;;
9557                         *)
9558                                 test -z "$cf_backup" && cf_backup=$cf_config
9559                                 ;;
9560                         esac
9561                 done
9562                 test -z "$PKG_CONFIG_LIBDIR" && PKG_CONFIG_LIBDIR=$cf_backup
9563                 AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
9564         fi
9565 fi
9566
9567 AC_SUBST(PKG_CONFIG_LIBDIR)
9568 ])dnl
9569 dnl ---------------------------------------------------------------------------
9570 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
9571 dnl ---------------
9572 dnl Check for POSIX thread library.
9573 AC_DEFUN([CF_WITH_PTHREAD],
9574 [
9575 AC_MSG_CHECKING(if you want to link with the pthread library)
9576 AC_ARG_WITH(pthread,
9577         [  --with-pthread          use POSIX thread library],
9578         [with_pthread=$withval],
9579         [with_pthread=no])
9580 AC_MSG_RESULT($with_pthread)
9581
9582 if test "$with_pthread" != no ; then
9583         AC_CHECK_HEADER(pthread.h,[
9584         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
9585
9586         for cf_lib_pthread in pthread c_r
9587         do
9588             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
9589             cf_save_LIBS="$LIBS"
9590             CF_ADD_LIB($cf_lib_pthread)
9591             AC_TRY_LINK([
9592 #include <pthread.h>
9593 ],[
9594                 int rc = pthread_create(0,0,0,0);
9595                 int r2 = pthread_mutexattr_settype(0, 0);
9596 ],[with_pthread=yes],[with_pthread=no])
9597             LIBS="$cf_save_LIBS"
9598             AC_MSG_RESULT($with_pthread)
9599             test "$with_pthread" = yes && break
9600         done
9601
9602         if test "$with_pthread" = yes ; then
9603             CF_ADD_LIB($cf_lib_pthread)
9604             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
9605         else
9606             AC_MSG_ERROR(Cannot link with pthread library)
9607         fi
9608         ])
9609 fi
9610 ])
9611 dnl ---------------------------------------------------------------------------
9612 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
9613 dnl -------------------
9614 dnl Allow library's release-version to be overridden.  Generally this happens when a
9615 dnl packager has incremented the release-version past that used in the original package,
9616 dnl and wishes to keep doing this.
9617 dnl
9618 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
9619 dnl and {package}_MINOR symbols
9620 dnl symbol.
9621 AC_DEFUN([CF_WITH_REL_VERSION],[
9622 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
9623 AC_ARG_WITH(rel-version,
9624 [  --with-rel-version=XXX  override derived release version],
9625 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
9626  cf_cv_rel_version=$withval])
9627 ifelse($1,,[
9628  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
9629 ],[
9630  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
9631  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
9632  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
9633  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
9634 ])
9635 ])dnl
9636 dnl ---------------------------------------------------------------------------
9637 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
9638 dnl ----------------
9639 dnl If we can compile with sysmouse, make it available unless it is not wanted.
9640 AC_DEFUN([CF_WITH_SYSMOUSE],[
9641 # not everyone has "test -c"
9642 if test -c /dev/sysmouse 2>/dev/null ; then
9643 AC_MSG_CHECKING(if you want to use sysmouse)
9644 AC_ARG_WITH(sysmouse,
9645         [  --with-sysmouse         use sysmouse (FreeBSD console)],
9646         [cf_with_sysmouse=$withval],
9647         [cf_with_sysmouse=maybe])
9648         if test "$cf_with_sysmouse" != no ; then
9649         AC_TRY_COMPILE([
9650 #include <osreldate.h>
9651 #if (__FreeBSD_version >= 400017)
9652 #include <sys/consio.h>
9653 #include <sys/fbio.h>
9654 #else
9655 #include <machine/console.h>
9656 #endif
9657 ],[
9658         struct mouse_info the_mouse;
9659         ioctl(0, CONS_MOUSECTL, &the_mouse);
9660 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
9661         fi
9662 AC_MSG_RESULT($cf_with_sysmouse)
9663 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
9664 fi
9665 ])dnl
9666 dnl ---------------------------------------------------------------------------
9667 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
9668 dnl ---------------
9669 dnl For testing, override the derived host system-type which is used to decide
9670 dnl things such as the linker commands used to build shared libraries.  This is
9671 dnl normally chosen automatically based on the type of system which you are
9672 dnl building on.  We use it for testing the configure script.
9673 dnl
9674 dnl This is different from the --host option: it is used only for testing parts
9675 dnl of the configure script which would not be reachable with --host since that
9676 dnl relies on the build environment being real, rather than mocked up.
9677 AC_DEFUN([CF_WITH_SYSTYPE],[
9678 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
9679 AC_ARG_WITH(system-type,
9680         [  --with-system-type=XXX  test: override derived host system-type],
9681 [AC_MSG_WARN(overriding system type to $withval)
9682         cf_cv_system_name=$withval
9683         host_os=$withval
9684 ])
9685 ])dnl
9686 dnl ---------------------------------------------------------------------------
9687 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
9688 dnl ----------------
9689 AC_DEFUN([CF_WITH_VALGRIND],[
9690 CF_NO_LEAKS_OPTION(valgrind,
9691         [  --with-valgrind         test: use valgrind],
9692         [USE_VALGRIND])
9693 ])dnl
9694 dnl ---------------------------------------------------------------------------
9695 dnl CF_WITH_VERSIONED_SYMS version: 10 updated: 2021/01/04 18:48:01
9696 dnl ----------------------
9697 dnl Use this when building shared library with ELF, to markup symbols with the
9698 dnl version identifier from the given input file.  Generally that identifier is
9699 dnl the same as the SONAME at which the symbol was first introduced.
9700 dnl
9701 dnl $1 = basename of the ".map" file (default $PACKAGE)
9702 AC_DEFUN([CF_WITH_VERSIONED_SYMS],
9703 [AC_REQUIRE([AC_PROG_FGREP])dnl
9704 AC_REQUIRE([AC_PROG_EGREP])dnl
9705
9706 AC_MSG_CHECKING(if versioned-symbols file should be used)
9707 AC_ARG_WITH(versioned-syms,
9708         [  --with-versioned-syms=X markup versioned symbols using ld],
9709         [with_versioned_syms=$withval],
9710         [with_versioned_syms=no])
9711 case "x$with_versioned_syms" in
9712 (xyes)
9713         with_versioned_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).map'
9714         AC_SUBST(PACKAGE)
9715         ;;
9716 (xno)
9717         ;;
9718 (x/*)
9719         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
9720         ;;
9721 (*)
9722         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
9723         with_versioned_syms=`pwd`/"$with_versioned_syms"
9724         ;;
9725 esac
9726 AC_MSG_RESULT($with_versioned_syms)
9727
9728 RESULTING_SYMS=
9729 VERSIONED_SYMS=
9730 WILDCARD_SYMS=
9731
9732 if test "x$with_versioned_syms" != xno
9733 then
9734         RESULTING_SYMS=$with_versioned_syms
9735         case "x$MK_SHARED_LIB" in
9736         (*-Wl,*)
9737                 VERSIONED_SYMS="-Wl,--version-script,\${RESULTING_SYMS}"
9738                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-Wl,%\\[$]{VERSIONED_SYMS} -Wl,%"`
9739                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
9740                 ;;
9741         (*-dy\ *)
9742                 VERSIONED_SYMS="-Wl,-M,\${RESULTING_SYMS}"
9743                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-dy%\\[$]{VERSIONED_SYMS} -dy%"`
9744                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
9745                 ;;
9746         (*)
9747                 AC_MSG_WARN(this system does not support versioned-symbols)
9748                 ;;
9749         esac
9750
9751         # Linux ld can selectively override scope, e.g., of symbols beginning with
9752         # "_" by first declaring some as global, and then using a wildcard to
9753         # declare the others as local.  Some other loaders cannot do this.  Check
9754         # by constructing a (very) simple shared library and inspecting its
9755         # symbols.
9756         if test "x$VERSIONED_SYMS" != "x"
9757         then
9758                 AC_MSG_CHECKING(if wildcards can be used to selectively omit symbols)
9759                 WILDCARD_SYMS=no
9760
9761                 # make sources
9762                 rm -f conftest.*
9763
9764                 cat >conftest.ver <<EOF
9765 module_1.0 {
9766 global:
9767         globalf1;
9768 local:
9769         localf1;
9770 };
9771 module_2.0 {
9772 global:
9773         globalf2;
9774 local:
9775         localf2;
9776         _*;
9777 } module_1.0;
9778 submodule_1.0 {
9779 global:
9780         subglobalf1;
9781         _ismissing;
9782 local:
9783         sublocalf1;
9784 };
9785 submodule_2.0 {
9786 global:
9787         subglobalf2;
9788 local:
9789         sublocalf2;
9790         _*;
9791 } submodule_1.0;
9792 EOF
9793                 cat >conftest.$ac_ext <<EOF
9794 #line __oline__ "configure"
9795 int     _ismissing(void) { return 1; }
9796 int     _localf1(void) { return 1; }
9797 int     _localf2(void) { return 2; }
9798 int     globalf1(void) { return 1; }
9799 int     globalf2(void) { return 2; }
9800 int     _sublocalf1(void) { return 1; }
9801 int     _sublocalf2(void) { return 2; }
9802 int     subglobalf1(void) { return 1; }
9803 int     subglobalf2(void) { return 2; }
9804 EOF
9805                 cat >conftest.mk <<EOF
9806 CC=${CC}
9807 CFLAGS=${CFLAGS}
9808 CPPFLAGS=${CPPFLAGS}
9809 LDFLAGS=${LDFLAGS}
9810 LIBS=${LIBS}
9811 VERSIONED_SYMS=${VERSIONED_SYMS}
9812 RESULTING_SYMS=conftest.ver
9813 MK_SHARED_LIB=${MK_SHARED_LIB}
9814 conftest.so: conftest.$ac_cv_objext
9815                 \$(MK_SHARED_LIB) conftest.$ac_cv_objext
9816 EOF
9817
9818                 # compile source, make library
9819                 if make -f conftest.mk 2>&AC_FD_CC >/dev/null
9820                 then
9821                         # test for missing symbol in either Data or Text section
9822                         cf_missing="`nm -P conftest.so 2>&AC_FD_CC |${FGREP-fgrep} _ismissing | ${EGREP-egrep} '[[      ]][[DT]][[      ]]'`"
9823                         test -n "$cf_missing" && WILDCARD_SYMS=yes
9824                 fi
9825                 AC_MSG_RESULT($WILDCARD_SYMS)
9826                 rm -f conftest.*
9827         fi
9828 fi
9829 AC_SUBST(RESULTING_SYMS)
9830 AC_SUBST(VERSIONED_SYMS)
9831 AC_SUBST(WILDCARD_SYMS)
9832 ])dnl
9833 dnl ---------------------------------------------------------------------------
9834 dnl CF_WITH_X11_RGB version: 2 updated: 2019/12/31 08:53:54
9835 dnl ---------------
9836 dnl Handle configure option "--with-x11-rgb", setting these shell
9837 dnl variables:
9838 dnl
9839 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
9840 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
9841 dnl
9842 dnl Most Linux's use this:
9843 dnl     /usr/share/X11/rgb.txt
9844 dnl Debian uses this:
9845 dnl     /etc/X11/rgb.txt
9846 dnl DragonFlyBSD ports uses this:
9847 dnl     /usr/pkg/lib/X11/rgb.txt
9848 dnl FreeBSD ports use these:
9849 dnl     /usr/local/lib/X11/rgb.txt
9850 dnl     /usr/local/share/X11/rgb.txt
9851 dnl Mandriva has these:
9852 dnl     /usr/lib/X11/rgb.txt
9853 dnl     /usr/lib64/X11/rgb.txt
9854 dnl NetBSD has these
9855 dnl     /usr/X11R7/lib/X11/rgb.txt
9856 dnl OpenSolaris uses
9857 dnl     32-bit:
9858 dnl     /usr/X11/etc/X11/rgb.txt
9859 dnl     /usr/X11/share/X11/rgb.txt
9860 dnl     /usr/X11/lib/X11/rgb.txt
9861 dnl OSX uses
9862 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
9863 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
9864 dnl     64-bit:
9865 dnl     /usr/X11/etc/X11/rgb.txt
9866 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
9867 dnl     /usr/X11/lib/amd64/X11/rgb.txt
9868 dnl Solaris10 uses (in this order):
9869 dnl     /usr/openwin/lib/X11/rgb.txt
9870 dnl     /usr/X11/lib/X11/rgb.txt
9871 AC_DEFUN([CF_WITH_X11_RGB],[
9872 AC_MSG_CHECKING(for X11 rgb file)
9873 AC_ARG_WITH(x11-rgb,
9874         [  --with-x11-rgb=FILE   file containing X11 rgb information (EPREFIX/lib/X11/rgb.txt)],
9875         [RGB_PATH=$withval],
9876         [RGB_PATH=auto])
9877
9878 if test "x[$]RGB_PATH" = xauto
9879 then
9880         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
9881         for cf_path in \
9882                 /opt/local/share/X11/rgb.txt \
9883                 /opt/X11/share/X11/rgb.txt \
9884                 /usr/share/X11/rgb.txt \
9885                 /usr/X11/share/X11/rgb.txt \
9886                 /usr/X11/lib/X11/rgb.txt \
9887                 /usr/lib/X11/rgb.txt \
9888                 /etc/X11/rgb.txt \
9889                 /usr/pkg/lib/X11/rgb.txt \
9890                 /usr/X11R7/lib/X11/rgb.txt \
9891                 /usr/X11R6/lib/X11/rgb.txt \
9892                 /usr/X11R5/lib/X11/rgb.txt \
9893                 /usr/X11R4/lib/X11/rgb.txt \
9894                 /usr/local/lib/X11/rgb.txt \
9895                 /usr/local/share/X11/rgb.txt \
9896                 /usr/lib64/X11/rgb.txt
9897         do
9898                 if test -f "$cf_path" ; then
9899                         RGB_PATH="$cf_path"
9900                         break
9901                 fi
9902         done
9903 else
9904         cf_path=$RGB_PATH
9905         CF_PATH_SYNTAX(cf_path)
9906 fi
9907
9908 AC_MSG_RESULT($RGB_PATH)
9909 AC_SUBST(RGB_PATH)
9910 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path",[Define to the full pathname of rgb.txt])
9911
9912 no_x11_rgb=
9913 if test "$RGB_PATH" = no
9914 then
9915         no_x11_rgb="#"
9916 fi
9917 AC_SUBST(no_x11_rgb)
9918 ])dnl
9919 dnl ---------------------------------------------------------------------------
9920 dnl CF_XOPEN_SOURCE version: 63 updated: 2022/12/29 10:10:26
9921 dnl ---------------
9922 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
9923 dnl or adapt to the vendor's definitions to get equivalent functionality,
9924 dnl without losing the common non-POSIX features.
9925 dnl
9926 dnl Parameters:
9927 dnl     $1 is the nominal value for _XOPEN_SOURCE
9928 dnl     $2 is the nominal value for _POSIX_C_SOURCE
9929 AC_DEFUN([CF_XOPEN_SOURCE],[
9930 AC_REQUIRE([AC_CANONICAL_HOST])
9931 AC_REQUIRE([CF_POSIX_VISIBLE])
9932
9933 if test "$cf_cv_posix_visible" = no; then
9934
9935 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
9936 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
9937 cf_xopen_source=
9938
9939 case "$host_os" in
9940 (aix[[4-7]]*)
9941         cf_xopen_source="-D_ALL_SOURCE"
9942         ;;
9943 (msys)
9944         cf_XOPEN_SOURCE=600
9945         ;;
9946 (darwin[[0-8]].*)
9947         cf_xopen_source="-D_APPLE_C_SOURCE"
9948         ;;
9949 (darwin*)
9950         cf_xopen_source="-D_DARWIN_C_SOURCE"
9951         cf_XOPEN_SOURCE=
9952         ;;
9953 (freebsd*|dragonfly*|midnightbsd*)
9954         # 5.x headers associate
9955         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
9956         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
9957         cf_POSIX_C_SOURCE=200112L
9958         cf_XOPEN_SOURCE=600
9959         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
9960         ;;
9961 (hpux11*)
9962         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
9963         ;;
9964 (hpux*)
9965         cf_xopen_source="-D_HPUX_SOURCE"
9966         ;;
9967 (irix[[56]].*)
9968         cf_xopen_source="-D_SGI_SOURCE"
9969         cf_XOPEN_SOURCE=
9970         ;;
9971 (linux*gnu|linux*gnuabi64|linux*gnuabin32|linux*gnueabi|linux*gnueabihf|linux*gnux32|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
9972         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
9973         ;;
9974 (minix*)
9975         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
9976         ;;
9977 (mirbsd*)
9978         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
9979         cf_XOPEN_SOURCE=
9980         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
9981         ;;
9982 (netbsd*)
9983         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
9984         ;;
9985 (openbsd[[6-9]]*)
9986         # OpenBSD 6.x has broken locale support, both compile-time and runtime.
9987         # see https://www.mail-archive.com/bugs@openbsd.org/msg13200.html
9988         # Abusing the conformance level is a workaround.
9989         AC_MSG_WARN(this system does not provide usable locale support)
9990         cf_xopen_source="-D_BSD_SOURCE"
9991         cf_XOPEN_SOURCE=700
9992         ;;
9993 (openbsd[[4-5]]*)
9994         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
9995         cf_xopen_source="-D_BSD_SOURCE"
9996         cf_XOPEN_SOURCE=600
9997         ;;
9998 (openbsd*)
9999         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
10000         ;;
10001 (osf[[45]]*)
10002         cf_xopen_source="-D_OSF_SOURCE"
10003         ;;
10004 (nto-qnx*)
10005         cf_xopen_source="-D_QNX_SOURCE"
10006         ;;
10007 (sco*)
10008         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
10009         ;;
10010 (solaris2.*)
10011         cf_xopen_source="-D__EXTENSIONS__"
10012         cf_cv_xopen_source=broken
10013         ;;
10014 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
10015         cf_XOPEN_SOURCE=
10016         cf_POSIX_C_SOURCE=
10017         ;;
10018 (*)
10019         CF_TRY_XOPEN_SOURCE
10020         cf_save_xopen_cppflags="$CPPFLAGS"
10021         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
10022         # Some of these niche implementations use copy/paste, double-check...
10023         if test "$cf_cv_xopen_source" != no ; then
10024                 CF_VERBOSE(checking if _POSIX_C_SOURCE inteferes)
10025                 AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,,[
10026                         AC_MSG_WARN(_POSIX_C_SOURCE definition is not usable)
10027                         CPPFLAGS="$cf_save_xopen_cppflags"])
10028         fi
10029         ;;
10030 esac
10031
10032 if test -n "$cf_xopen_source" ; then
10033         CF_APPEND_CFLAGS($cf_xopen_source,true)
10034 fi
10035
10036 dnl In anything but the default case, we may have system-specific setting
10037 dnl which is still not guaranteed to provide all of the entrypoints that
10038 dnl _XOPEN_SOURCE would yield.
10039 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
10040         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
10041         AC_TRY_COMPILE([#include <stdlib.h>],[
10042 #ifndef _XOPEN_SOURCE
10043 make an error
10044 #endif],
10045         [cf_XOPEN_SOURCE_set=yes],
10046         [cf_XOPEN_SOURCE_set=no])
10047         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
10048         if test "$cf_XOPEN_SOURCE_set" = yes
10049         then
10050                 AC_TRY_COMPILE([#include <stdlib.h>],[
10051 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
10052 make an error
10053 #endif],
10054                 [cf_XOPEN_SOURCE_set_ok=yes],
10055                 [cf_XOPEN_SOURCE_set_ok=no])
10056                 if test "$cf_XOPEN_SOURCE_set_ok" = no
10057                 then
10058                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
10059                 fi
10060         else
10061                 CF_TRY_XOPEN_SOURCE
10062         fi
10063 fi
10064 fi # cf_cv_posix_visible
10065 ])
10066 dnl ---------------------------------------------------------------------------
10067 dnl CF__SED_TRIMBLANKS version: 1 updated: 2021/01/02 09:31:20
10068 dnl ------------------
10069 dnl Trim something using sed, then trim extra whitespace
10070 dnl $1 = extra parameters, e.g., in CF_STRIP_G_OPT
10071 define([CF__SED_TRIMBLANKS],[sed ifelse($1,,,[$1] )-e 's%[[     ]]% %g' -e 's% [[ ]]*% %g' -e 's%^ %%' -e 's% [$]%%'])dnl
10072 dnl ---------------------------------------------------------------------------
10073 dnl CF__XOPEN_SOURCE_BODY version: 1 updated: 2022/09/10 15:17:35
10074 dnl ---------------------
10075 dnl body of test when test-compiling for _XOPEN_SOURCE check
10076 define([CF__XOPEN_SOURCE_BODY],
10077 [
10078 #ifndef _XOPEN_SOURCE
10079 make an error
10080 #endif
10081 ])
10082 dnl ---------------------------------------------------------------------------
10083 dnl CF__XOPEN_SOURCE_HEAD version: 1 updated: 2022/09/10 15:17:03
10084 dnl ---------------------
10085 dnl headers to include when test-compiling for _XOPEN_SOURCE check
10086 define([CF__XOPEN_SOURCE_HEAD],
10087 [
10088 #include <stdlib.h>
10089 #include <string.h>
10090 #include <sys/types.h>
10091 ])