aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2022,2023 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: aclocal.m4,v 1.1048 2023/06/03 19:19:41 tom Exp $
  33 dnl Macros used in NCURSES auto-configuration script.
  34 dnl
  35 dnl These macros are maintained separately from NCURSES.  The copyright on
  36 dnl this file applies to the aggregation of macros and does not affect use of
  37 dnl these macros in other applications.
  38 dnl
  39 dnl See these pages for additional information:
  40 dnl             https://invisible-island.net/autoconf/
  41 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  42 dnl
  43 dnl ---------------------------------------------------------------------------
  44 dnl ---------------------------------------------------------------------------
  45 dnl AM_LANGINFO_CODESET version: 7 updated: 2023/01/11 04:05:23
  46 dnl -------------------
  47 dnl Inserted as requested by gettext 0.10.40
  48 dnl File from /usr/share/aclocal
  49 dnl codeset.m4
  50 dnl ====================
  51 dnl serial AM1
  52 dnl
  53 dnl From Bruno Haible.
  54 AC_DEFUN([AM_LANGINFO_CODESET],
  55 [
  56 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  57         [AC_TRY_LINK([
  58 $ac_includes_default
  59 #include <langinfo.h>],
  60         [char* cs = nl_langinfo(CODESET); (void)cs],
  61         am_cv_langinfo_codeset=yes,
  62         am_cv_langinfo_codeset=no)
  63         ])
  64         if test "$am_cv_langinfo_codeset" = yes; then
  65                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  66                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  67         fi
  68 ])dnl
  69 dnl ---------------------------------------------------------------------------
  70 dnl CF_ABI_DEFAULTS version: 4 updated: 2023/01/07 16:32:06
  71 dnl ---------------
  72 dnl Provide configure-script defaults for different ncurses ABIs.
  73 AC_DEFUN([CF_ABI_DEFAULTS],[
  74 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  75
  76 # ABI 5 defaults:
  77 cf_dft_ccharw_max=5
  78 cf_dft_chtype=auto
  79 cf_dft_ext_colors=no
  80 cf_dft_ext_const=no
  81 cf_dft_ext_mouse=no
  82 cf_dft_ext_putwin=no
  83 cf_dft_ext_spfuncs=no
  84 cf_dft_filter_syms=no
  85 cf_dft_interop=no
  86 cf_dft_mmask_t=auto
  87 cf_dft_opaque_curses=no
  88 cf_dft_ordinate_type=short
  89 cf_dft_signed_char=no
  90 cf_dft_tparm_arg=long
  91 cf_dft_with_lp64=no
  92
  93 # ABI 6 defaults:
  94 case x$cf_cv_abi_default in
  95 (x[[6789]])
  96         cf_dft_chtype=uint32_t
  97         cf_dft_ext_colors=yes
  98         cf_dft_ext_const=yes
  99         cf_dft_ext_mouse=yes
 100         cf_dft_ext_putwin=yes
 101         cf_dft_ext_spfuncs=yes
 102         cf_dft_filter_syms=yes
 103         cf_dft_interop=yes
 104         cf_dft_mmask_t=uint32_t
 105         cf_dft_tparm_arg=intptr_t
 106         cf_dft_with_lp64=yes
 107         ;;
 108 esac
 109
 110 # ABI 7 defaults:
 111 case x$cf_cv_abi_default in
 112 (x[[789]])
 113         cf_dft_ccharw_max=6
 114         cf_dft_mmask_t=uint64_t
 115         cf_dft_opaque_curses=yes
 116         cf_dft_ordinate_type=int
 117         cf_dft_signed_char=yes
 118         # also: remove the wgetch-events feature in ABI 7
 119         ;;
 120 esac
 121 ])dnl
 122 dnl ---------------------------------------------------------------------------
 123 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 124 dnl ------------------
 125 dnl Conditionally generate script according to whether we're using a given autoconf.
 126 dnl
 127 dnl $1 = version to compare against
 128 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 129 dnl $3 = code to use if AC_ACVERSION is older than $1.
 130 define([CF_ACVERSION_CHECK],
 131 [
 132 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 133 ifdef([m4_version_compare],
 134 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 135 [CF_ACVERSION_COMPARE(
 136 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 137 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 138 dnl ---------------------------------------------------------------------------
 139 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 140 dnl --------------------
 141 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 142 dnl                      MAJOR2, MINOR2, TERNARY2,
 143 dnl                      PRINTABLE2, not FOUND, FOUND)
 144 define([CF_ACVERSION_COMPARE],
 145 [ifelse(builtin([eval], [$2 < $5]), 1,
 146 [ifelse([$8], , ,[$8])],
 147 [ifelse([$9], , ,[$9])])])dnl
 148 dnl ---------------------------------------------------------------------------
 149 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 150 dnl -------------------
 151 dnl Construct the list of include-options for the C programs in the Ada95
 152 dnl binding.
 153 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 154 [
 155 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 156 if test "$srcdir" != "."; then
 157         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 158 fi
 159 if test "$GCC" != yes; then
 160         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 161 elif test "$includedir" != "/usr/include"; then
 162         if test "$includedir" = '${prefix}/include' ; then
 163                 if test x$prefix != x/usr ; then
 164                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 165                 fi
 166         else
 167                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 168         fi
 169 fi
 170 AC_SUBST(ACPPFLAGS)
 171 ])dnl
 172 dnl ---------------------------------------------------------------------------
 173 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 174 dnl ---------------
 175 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 176 AC_DEFUN([CF_ADD_ADAFLAGS],[
 177         ADAFLAGS="$ADAFLAGS $1"
 178         AC_SUBST(ADAFLAGS)
 179 ])dnl
 180 dnl ---------------------------------------------------------------------------
 181 dnl CF_ADD_CFLAGS version: 15 updated: 2020/12/31 10:54:15
 182 dnl -------------
 183 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 184 dnl $1 = flags to add
 185 dnl $2 = if given makes this macro verbose.
 186 dnl
 187 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 188 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 189 dnl confused by the quotes (which require backslashes to keep them usable).
 190 AC_DEFUN([CF_ADD_CFLAGS],
 191 [
 192 cf_fix_cppflags=no
 193 cf_new_cflags=
 194 cf_new_cppflags=
 195 cf_new_extra_cppflags=
 196
 197 for cf_add_cflags in $1
 198 do
 199 case "$cf_fix_cppflags" in
 200 (no)
 201         case "$cf_add_cflags" in
 202         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 203                 case "$cf_add_cflags" in
 204                 (-D*)
 205                         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 206
 207                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 208                                 && test -z "${cf_tst_cflags}" \
 209                                 && cf_fix_cppflags=yes
 210
 211                         if test "$cf_fix_cppflags" = yes ; then
 212                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 213                                 continue
 214                         elif test "${cf_tst_cflags}" = "\"'" ; then
 215                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 216                                 continue
 217                         fi
 218                         ;;
 219                 esac
 220                 case "$CPPFLAGS" in
 221                 (*$cf_add_cflags)
 222                         ;;
 223                 (*)
 224                         case "$cf_add_cflags" in
 225                         (-D*)
 226                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 227                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 228                                 ;;
 229                         esac
 230                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 231                         ;;
 232                 esac
 233                 ;;
 234         (*)
 235                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 236                 ;;
 237         esac
 238         ;;
 239 (yes)
 240         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 241
 242         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^[[^"]]*"'\''//'`
 243
 244         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 245                 && test -z "${cf_tst_cflags}" \
 246                 && cf_fix_cppflags=no
 247         ;;
 248 esac
 249 done
 250
 251 if test -n "$cf_new_cflags" ; then
 252         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 253         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 254 fi
 255
 256 if test -n "$cf_new_cppflags" ; then
 257         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 258         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 259 fi
 260
 261 if test -n "$cf_new_extra_cppflags" ; then
 262         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 263         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 264 fi
 265
 266 AC_SUBST(EXTRA_CPPFLAGS)
 267
 268 ])dnl
 269 dnl ---------------------------------------------------------------------------
 270 dnl CF_ADD_CXXFLAGS version: 1 updated: 2020/04/04 16:16:13
 271 dnl ---------------
 272 dnl Copy non-preprocessor flags to $CXXFLAGS, preprocessor flags to $CPPFLAGS
 273 dnl The second parameter if given makes this macro verbose.
 274 dnl
 275 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 276 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 277 dnl confused by the quotes (which require backslashes to keep them usable).
 278 AC_DEFUN([CF_ADD_CXXFLAGS],
 279 [
 280 cf_save_CXXFLAGS="$CFLAGS"
 281 CFLAGS="$CXXFLAGS"
 282 CF_ADD_CFLAGS($1 ifelse($2,,,[,$2]))
 283 CXXFLAGS="$CFLAGS"
 284 CFLAGS="$cf_save_CXXFLAGS"
 285 ])dnl
 286 dnl ---------------------------------------------------------------------------
 287 dnl CF_ADD_INCDIR version: 17 updated: 2021/09/04 06:35:04
 288 dnl -------------
 289 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it is
 290 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 291 dnl but old versions (and some misinstalled ones) need that.  To make things
 292 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 293 dnl the include-path).
 294 AC_DEFUN([CF_ADD_INCDIR],
 295 [
 296 if test -n "$1" ; then
 297   for cf_add_incdir in $1
 298   do
 299         while test "$cf_add_incdir" != /usr/include
 300         do
 301           if test -d "$cf_add_incdir"
 302           then
 303                 cf_have_incdir=no
 304                 if test -n "$CFLAGS$CPPFLAGS" ; then
 305                   # a loop is needed to ensure we can add subdirs of existing dirs
 306                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 307                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 308                           cf_have_incdir=yes; break
 309                         fi
 310                   done
 311                 fi
 312
 313                 if test "$cf_have_incdir" = no ; then
 314                   if test "$cf_add_incdir" = /usr/local/include ; then
 315                         if test "$GCC" = yes
 316                         then
 317                           cf_save_CPPFLAGS=$CPPFLAGS
 318                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 319                           AC_TRY_COMPILE([#include <stdio.h>],
 320                                   [printf("Hello")],
 321                                   [],
 322                                   [cf_have_incdir=yes])
 323                           CPPFLAGS=$cf_save_CPPFLAGS
 324                         fi
 325                   fi
 326                 fi
 327
 328                 if test "$cf_have_incdir" = no ; then
 329                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 330                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 331
 332                   cf_top_incdir=`echo "$cf_add_incdir" | sed -e 's%/include/.*$%/include%'`
 333                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 334                   cf_add_incdir="$cf_top_incdir"
 335                 else
 336                   break
 337                 fi
 338           else
 339                 break
 340           fi
 341         done
 342   done
 343 fi
 344 ])dnl
 345 dnl ---------------------------------------------------------------------------
 346 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 347 dnl ----------
 348 dnl Add a library, used to enforce consistency.
 349 dnl
 350 dnl $1 = library to add, without the "-l"
 351 dnl $2 = variable to update (default $LIBS)
 352 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 353 dnl ---------------------------------------------------------------------------
 354 dnl CF_ADD_LIBDIR version: 11 updated: 2020/12/31 20:19:42
 355 dnl -------------
 356 dnl     Adds to the library-path
 357 dnl
 358 dnl     Some machines have trouble with multiple -L options.
 359 dnl
 360 dnl $1 is the (list of) directory(s) to add
 361 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 362 dnl
 363 AC_DEFUN([CF_ADD_LIBDIR],
 364 [
 365 if test -n "$1" ; then
 366         for cf_add_libdir in $1
 367         do
 368                 if test "$cf_add_libdir" = /usr/lib ; then
 369                         :
 370                 elif test -d "$cf_add_libdir"
 371                 then
 372                         cf_have_libdir=no
 373                         if test -n "$LDFLAGS$LIBS" ; then
 374                                 # a loop is needed to ensure we can add subdirs of existing dirs
 375                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 376                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 377                                                 cf_have_libdir=yes; break
 378                                         fi
 379                                 done
 380                         fi
 381                         if test "$cf_have_libdir" = no ; then
 382                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 383                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 384                         fi
 385                 fi
 386         done
 387 fi
 388 ])dnl
 389 dnl ---------------------------------------------------------------------------
 390 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
 391 dnl -----------
 392 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 393 dnl prepended to an existing list, since their dependencies are assumed to
 394 dnl already exist in the list.
 395 dnl
 396 dnl $1 = libraries to add, with the "-l", etc.
 397 dnl $2 = variable to update (default $LIBS)
 398 AC_DEFUN([CF_ADD_LIBS],[
 399 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
 400 # reverse order
 401 cf_add_0lib=
 402 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
 403 # filter duplicates
 404 for cf_add_1lib in $cf_add_0lib; do
 405         for cf_add_2lib in $cf_add_libs; do
 406                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
 407                         cf_add_1lib=
 408                         break
 409                 fi
 410         done
 411         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
 412 done
 413 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 414 ])dnl
 415 dnl ---------------------------------------------------------------------------
 416 dnl CF_ADD_SUBDIR_PATH version: 5 updated: 2020/12/31 20:19:42
 417 dnl ------------------
 418 dnl Append to a search-list for a nonstandard header/lib-file
 419 dnl     $1 = the variable to return as result
 420 dnl     $2 = the package name
 421 dnl     $3 = the subdirectory, e.g., bin, include or lib
 422 dnl $4 = the directory under which we will test for subdirectories
 423 dnl $5 = a directory that we do not want $4 to match
 424 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 425 [
 426 test "x$4" != "x$5" && \
 427 test -d "$4" && \
 428 ifelse([$5],NONE,,[{ test -z "$5" || test "x$5" = xNONE || test "x$4" != "x$5"; } &&]) {
 429         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 430         test -d "$4/$3" &&          $1="[$]$1 $4/$3"
 431         test -d "$4/$3/$2" &&       $1="[$]$1 $4/$3/$2"
 432         test -d "$4/$3/$2/$3" &&    $1="[$]$1 $4/$3/$2/$3"
 433         test -d "$4/$2/$3" &&       $1="[$]$1 $4/$2/$3"
 434         test -d "$4/$2/$3/$2" &&    $1="[$]$1 $4/$2/$3/$2"
 435 }
 436 ])dnl
 437 dnl ---------------------------------------------------------------------------
 438 dnl CF_APPEND_CFLAGS version: 3 updated: 2021/09/05 17:25:40
 439 dnl ----------------
 440 dnl Use CF_ADD_CFLAGS after first checking for potential redefinitions.
 441 dnl $1 = flags to add
 442 dnl $2 = if given makes this macro verbose.
 443 define([CF_APPEND_CFLAGS],
 444 [
 445 for cf_add_cflags in $1
 446 do
 447         case "x$cf_add_cflags" in
 448         (x-[[DU]]*)
 449                 CF_REMOVE_CFLAGS($cf_add_cflags,CFLAGS,[$2])
 450                 CF_REMOVE_CFLAGS($cf_add_cflags,CPPFLAGS,[$2])
 451                 ;;
 452         esac
 453         CF_ADD_CFLAGS([$cf_add_cflags],[$2])
 454 done
 455 ])dnl
 456 dnl ---------------------------------------------------------------------------
 457 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 458 dnl --------------
 459 dnl use this macro for appending text without introducing an extra blank at
 460 dnl the beginning
 461 define([CF_APPEND_TEXT],
 462 [
 463         test -n "[$]$1" && $1="[$]$1 "
 464         $1="[$]{$1}$2"
 465 ])dnl
 466 dnl ---------------------------------------------------------------------------
 467 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 468 dnl --------------
 469 dnl Allow user to disable a normally-on option.
 470 AC_DEFUN([CF_ARG_DISABLE],
 471 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 472 dnl ---------------------------------------------------------------------------
 473 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 474 dnl -------------
 475 dnl Allow user to enable a normally-off option.
 476 AC_DEFUN([CF_ARG_ENABLE],
 477 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 478 dnl ---------------------------------------------------------------------------
 479 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 480 dnl -------------
 481 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 482 dnl values.
 483 dnl
 484 dnl Parameters:
 485 dnl $1 = option name
 486 dnl $2 = help-string
 487 dnl $3 = action to perform if option is not default
 488 dnl $4 = action if perform if option is default
 489 dnl $5 = default option value (either 'yes' or 'no')
 490 AC_DEFUN([CF_ARG_OPTION],
 491 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 492         if test "$enableval" != "$5" ; then
 493 ifelse([$3],,[    :]dnl
 494 ,[    $3]) ifelse([$4],,,[
 495         else
 496                 $4])
 497         fi],[enableval=$5 ifelse([$4],,,[
 498         $4
 499 ])dnl
 500 ])])dnl
 501 dnl ---------------------------------------------------------------------------
 502 dnl CF_AR_FLAGS version: 9 updated: 2021/01/01 13:31:04
 503 dnl -----------
 504 dnl Check for suitable "ar" (archiver) options for updating an archive.
 505 dnl
 506 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 507 dnl as well as a workaround for breakage of make's archive rules by the GNU
 508 dnl binutils "ar" program.
 509 AC_DEFUN([CF_AR_FLAGS],[
 510 AC_REQUIRE([CF_PROG_AR])
 511
 512 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 513         case "$cf_cv_system_name" in
 514         (*-msvc*)
 515                 cf_cv_ar_flags=''
 516                 cat >mk_static_lib.sh <<-EOF
 517                 #!$SHELL
 518                 MSVC_BIN="[$]AR"
 519                 out="\[$]1"
 520                 shift
 521                 exec \[$]MSVC_BIN -out:"\[$]out" \[$]@
 522                 EOF
 523                 chmod +x mk_static_lib.sh
 524                 AR=`pwd`/mk_static_lib.sh
 525                 ;;
 526         (*)
 527                 cf_cv_ar_flags=unknown
 528                 for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 529                 do
 530
 531                         # check if $ARFLAGS already contains this choice
 532                         if test "x$ARFLAGS" != "x" ; then
 533                                 cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 534                                 if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 535                                         cf_cv_ar_flags=
 536                                         break
 537                                 fi
 538                         fi
 539
 540                         rm -f "conftest.$ac_cv_objext"
 541                         rm -f conftest.a
 542
 543                         cat >"conftest.$ac_ext" <<EOF
 544 #line __oline__ "configure"
 545 int     testdata[[3]] = { 123, 456, 789 };
 546 EOF
 547                         if AC_TRY_EVAL(ac_compile) ; then
 548                                 echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 549                                 $AR $ARFLAGS "$cf_ar_flags" conftest.a "conftest.$ac_cv_objext" 2>&AC_FD_CC 1>/dev/null
 550                                 if test -f conftest.a ; then
 551                                         cf_cv_ar_flags="$cf_ar_flags"
 552                                         break
 553                                 fi
 554                         else
 555                                 CF_VERBOSE(cannot compile test-program)
 556                                 break
 557                         fi
 558                 done
 559                 rm -f conftest.a "conftest.$ac_ext" "conftest.$ac_cv_objext"
 560                 ;;
 561         esac
 562 ])
 563
 564 if test -n "$ARFLAGS" ; then
 565         if test -n "$cf_cv_ar_flags" ; then
 566                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 567         fi
 568 else
 569         ARFLAGS=$cf_cv_ar_flags
 570 fi
 571
 572 AC_SUBST(ARFLAGS)
 573 ])
 574 dnl ---------------------------------------------------------------------------
 575 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 576 dnl -----------------
 577 dnl Check if awk can handle big strings using printf.  Some older versions of
 578 dnl awk choke on large strings passed via "%s".
 579 dnl
 580 dnl $1 = desired string size
 581 dnl $2 = variable to set with result
 582 AC_DEFUN([CF_AWK_BIG_PRINTF],
 583 [
 584         case x$AWK in
 585         (x)
 586                 eval $2=no
 587                 ;;
 588         (*)
 589                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 590                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 591                         eval $2=yes
 592                 else
 593                         eval $2=no
 594                 fi
 595                 ;;
 596         esac
 597 ])dnl
 598 dnl ---------------------------------------------------------------------------
 599 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 600 dnl ------------
 601 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 602 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 603 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 604 dnl
 605 dnl Treat the configuration-variable specially here, since we're directly
 606 dnl substituting its value (i.e., 1/0).
 607 dnl
 608 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 609 AC_DEFUN([CF_BOOL_DECL],
 610 [
 611 AC_MSG_CHECKING(if we should include stdbool.h)
 612
 613 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 614         AC_TRY_COMPILE([],[bool foo = false],
 615                 [cf_cv_header_stdbool_h=0],
 616                 [AC_TRY_COMPILE([
 617 #ifndef __BEOS__
 618 #include <stdbool.h>
 619 #endif
 620 ],[bool foo = false],
 621                         [cf_cv_header_stdbool_h=1],
 622                         [cf_cv_header_stdbool_h=0])])])
 623
 624 if test "$cf_cv_header_stdbool_h" = 1
 625 then    AC_MSG_RESULT(yes)
 626 else    AC_MSG_RESULT(no)
 627 fi
 628
 629 AC_MSG_CHECKING([for builtin bool type])
 630
 631 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 632         AC_TRY_COMPILE([
 633 #include <stdio.h>
 634 #include <sys/types.h>
 635 ],[bool x = false],
 636                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 637                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 638         ])
 639
 640 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 641 then    AC_MSG_RESULT(yes)
 642 else    AC_MSG_RESULT(no)
 643 fi
 644 ])dnl
 645 dnl ---------------------------------------------------------------------------
 646 dnl CF_BOOL_SIZE version: 20 updated: 2023/02/18 17:41:25
 647 dnl ------------
 648 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 649 dnl Don't bother looking for bool.h, since it has been deprecated.
 650 dnl
 651 dnl If the current compiler is C rather than C++, we get the bool definition
 652 dnl from <stdbool.h>.
 653 AC_DEFUN([CF_BOOL_SIZE],
 654 [
 655 AC_CHECK_SIZEOF(bool,,[
 656 $ac_includes_default
 657
 658 #if defined(__cplusplus)
 659
 660 #ifdef HAVE_GXX_BUILTIN_H
 661 #include <g++/builtin.h>
 662 #elif HAVE_GPP_BUILTIN_H
 663 #include <gpp/builtin.h>
 664 #elif HAVE_BUILTIN_H
 665 #include <builtin.h>
 666 #endif
 667
 668 #else
 669
 670 #if $cf_cv_header_stdbool_h
 671 #include <stdbool.h>
 672 #endif
 673
 674 #endif
 675 ])
 676
 677 AC_CACHE_CHECK(for type of bool, cf_cv_type_of_bool,[
 678         rm -f cf_test.out
 679         AC_TRY_RUN([
 680 $ac_includes_default
 681
 682 #if defined(__cplusplus)
 683
 684 #ifdef HAVE_GXX_BUILTIN_H
 685 #include <g++/builtin.h>
 686 #elif HAVE_GPP_BUILTIN_H
 687 #include <gpp/builtin.h>
 688 #elif HAVE_BUILTIN_H
 689 #include <builtin.h>
 690 #endif
 691
 692 #else
 693
 694 #if $cf_cv_header_stdbool_h
 695 #include <stdbool.h>
 696 #endif
 697
 698 #endif
 699
 700 int main(void)
 701 {
 702         FILE *fp = fopen("cf_test.out", "w");
 703         if (fp != 0) {
 704                 bool x = true;
 705                 if ((bool)(-x) >= 0)
 706                         fputs("unsigned ", fp);
 707                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 708                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 709                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 710                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 711                 fclose(fp);
 712         }
 713         ${cf_cv_main_return:-return}(0);
 714 }
 715                 ],
 716                 [cf_cv_type_of_bool=`cat cf_test.out`
 717                  if test -z "$cf_cv_type_of_bool"; then
 718                    cf_cv_type_of_bool=unknown
 719                  fi],
 720                 [cf_cv_type_of_bool=unknown],
 721                 [
 722                 case x$ac_cv_sizeof_bool in
 723                 (x1) cf_cv_type_of_bool="unsigned char";;
 724                 (x2) cf_cv_type_of_bool="unsigned short";;
 725                 (x4) cf_cv_type_of_bool="unsigned int";;
 726                 (x8) cf_cv_type_of_bool="unsigned long";;
 727                 (*)  cf_cv_type_of_bool=unknown;;
 728                 esac
 729                 ])
 730         rm -f cf_test.out
 731 ])
 732
 733 if test "$cf_cv_type_of_bool" = unknown ; then
 734         case .$NCURSES_BOOL in
 735         (.auto|.) NCURSES_BOOL=unsigned;;
 736         esac
 737         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 738         cf_cv_type_of_bool=$NCURSES_BOOL
 739 fi
 740 ])dnl
 741 dnl ---------------------------------------------------------------------------
 742 dnl CF_BUILD_CC version: 11 updated: 2022/12/04 15:40:08
 743 dnl -----------
 744 dnl If we're cross-compiling, allow the user to override the tools and their
 745 dnl options.  The configure script is oriented toward identifying the host
 746 dnl compiler, etc., but we need a build compiler to generate parts of the
 747 dnl source.
 748 dnl
 749 dnl $1 = default for $CPPFLAGS
 750 dnl $2 = default for $LIBS
 751 AC_DEFUN([CF_BUILD_CC],[
 752 CF_ACVERSION_CHECK(2.52,,
 753         [AC_REQUIRE([CF_PROG_EXT])])
 754 if test "$cross_compiling" = yes ; then
 755
 756         # defaults that we might want to override
 757         : ${BUILD_CFLAGS:=''}
 758         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 759         : ${BUILD_LDFLAGS:=''}
 760         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 761         : ${BUILD_EXEEXT:='$x'}
 762         : ${BUILD_OBJEXT:='o'}
 763
 764         AC_ARG_WITH(build-cc,
 765                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 766                 [BUILD_CC="$withval"],
 767                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 768         AC_MSG_CHECKING(for native build C compiler)
 769         AC_MSG_RESULT($BUILD_CC)
 770
 771         AC_MSG_CHECKING(for native build C preprocessor)
 772         AC_ARG_WITH(build-cpp,
 773                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 774                 [BUILD_CPP="$withval"],
 775                 [BUILD_CPP='${BUILD_CC} -E'])
 776         AC_MSG_RESULT($BUILD_CPP)
 777
 778         AC_MSG_CHECKING(for native build C flags)
 779         AC_ARG_WITH(build-cflags,
 780                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 781                 [BUILD_CFLAGS="$withval"])
 782         AC_MSG_RESULT($BUILD_CFLAGS)
 783
 784         AC_MSG_CHECKING(for native build C preprocessor-flags)
 785         AC_ARG_WITH(build-cppflags,
 786                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 787                 [BUILD_CPPFLAGS="$withval"])
 788         AC_MSG_RESULT($BUILD_CPPFLAGS)
 789
 790         AC_MSG_CHECKING(for native build linker-flags)
 791         AC_ARG_WITH(build-ldflags,
 792                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 793                 [BUILD_LDFLAGS="$withval"])
 794         AC_MSG_RESULT($BUILD_LDFLAGS)
 795
 796         AC_MSG_CHECKING(for native build linker-libraries)
 797         AC_ARG_WITH(build-libs,
 798                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 799                 [BUILD_LIBS="$withval"])
 800         AC_MSG_RESULT($BUILD_LIBS)
 801
 802         # this assumes we're on Unix.
 803         BUILD_EXEEXT=
 804         BUILD_OBJEXT=o
 805
 806         : ${BUILD_CC:='${CC}'}
 807
 808         AC_MSG_CHECKING(if the build-compiler "$BUILD_CC" works)
 809
 810         cf_save_crossed=$cross_compiling
 811         cf_save_ac_link=$ac_link
 812         cross_compiling=no
 813         cf_build_cppflags=$BUILD_CPPFLAGS
 814         test "$cf_build_cppflags" = "#" && cf_build_cppflags=
 815         ac_link='$BUILD_CC -o "conftest$ac_exeext" $BUILD_CFLAGS $cf_build_cppflags $BUILD_LDFLAGS "conftest.$ac_ext" $BUILD_LIBS >&AS_MESSAGE_LOG_FD'
 816
 817         AC_TRY_RUN([#include <stdio.h>
 818                 int main(int argc, char *argv[])
 819                 {
 820                         ${cf_cv_main_return:-return}(argc < 0 || argv == 0 || argv[0] == 0);
 821                 }
 822         ],
 823                 cf_ok_build_cc=yes,
 824                 cf_ok_build_cc=no,
 825                 cf_ok_build_cc=unknown)
 826
 827         cross_compiling=$cf_save_crossed
 828         ac_link=$cf_save_ac_link
 829
 830         AC_MSG_RESULT($cf_ok_build_cc)
 831
 832         if test "$cf_ok_build_cc" != yes
 833         then
 834                 AC_MSG_ERROR([Cross-build requires two compilers.
 835 Use --with-build-cc to specify the native compiler.])
 836         fi
 837
 838 else
 839         : ${BUILD_CC:='${CC}'}
 840         : ${BUILD_CPP:='${CPP}'}
 841         : ${BUILD_CFLAGS:='${CFLAGS}'}
 842         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 843         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 844         : ${BUILD_LIBS:='${LIBS}'}
 845         : ${BUILD_EXEEXT:='$x'}
 846         : ${BUILD_OBJEXT:='o'}
 847 fi
 848
 849 AC_SUBST(BUILD_CC)
 850 AC_SUBST(BUILD_CPP)
 851 AC_SUBST(BUILD_CFLAGS)
 852 AC_SUBST(BUILD_CPPFLAGS)
 853 AC_SUBST(BUILD_LDFLAGS)
 854 AC_SUBST(BUILD_LIBS)
 855 AC_SUBST(BUILD_EXEEXT)
 856 AC_SUBST(BUILD_OBJEXT)
 857 ])dnl
 858 dnl ---------------------------------------------------------------------------
 859 dnl CF_C11_NORETURN version: 4 updated: 2023/02/18 17:41:25
 860 dnl ---------------
 861 AC_DEFUN([CF_C11_NORETURN],
 862 [
 863 AC_MSG_CHECKING(if you want to use C11 _Noreturn feature)
 864 CF_ARG_ENABLE(stdnoreturn,
 865         [  --enable-stdnoreturn    enable C11 _Noreturn feature for diagnostics],
 866         [enable_stdnoreturn=yes],
 867         [enable_stdnoreturn=no])
 868 AC_MSG_RESULT($enable_stdnoreturn)
 869
 870 if test $enable_stdnoreturn = yes; then
 871 AC_CACHE_CHECK([for C11 _Noreturn feature], cf_cv_c11_noreturn,
 872         [AC_TRY_COMPILE([
 873 $ac_includes_default
 874 #include <stdnoreturn.h>
 875 static _Noreturn void giveup(void) { exit(0); }
 876         ],
 877         [if (feof(stdin)) giveup()],
 878         cf_cv_c11_noreturn=yes,
 879         cf_cv_c11_noreturn=no)
 880         ])
 881 else
 882         cf_cv_c11_noreturn=no,
 883 fi
 884
 885 if test "$cf_cv_c11_noreturn" = yes; then
 886         AC_DEFINE(HAVE_STDNORETURN_H, 1,[Define if <stdnoreturn.h> header is available and working])
 887         AC_DEFINE_UNQUOTED(STDC_NORETURN,_Noreturn,[Define if C11 _Noreturn keyword is supported])
 888         HAVE_STDNORETURN_H=1
 889 else
 890         HAVE_STDNORETURN_H=0
 891 fi
 892
 893 AC_SUBST(HAVE_STDNORETURN_H)
 894 AC_SUBST(STDC_NORETURN)
 895 ])dnl
 896 dnl ---------------------------------------------------------------------------
 897 dnl CF_CC_ENV_FLAGS version: 11 updated: 2023/02/20 11:15:46
 898 dnl ---------------
 899 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 900 dnl into CC.  This will not help with broken scripts that wrap the compiler
 901 dnl with options, but eliminates a more common category of user confusion.
 902 dnl
 903 dnl In particular, it addresses the problem of being able to run the C
 904 dnl preprocessor in a consistent manner.
 905 dnl
 906 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 907 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 908 dnl outweighs that limitation.
 909 AC_DEFUN([CF_CC_ENV_FLAGS],
 910 [
 911 # This should have been defined by AC_PROG_CC
 912 : "${CC:=cc}"
 913
 914 AC_MSG_CHECKING(\$CFLAGS variable)
 915 case "x$CFLAGS" in
 916 (*-[[IUD]]*)
 917         AC_MSG_RESULT(broken)
 918         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 919         cf_flags="$CFLAGS"
 920         CFLAGS=
 921         for cf_arg in $cf_flags
 922         do
 923                 CF_ADD_CFLAGS($cf_arg)
 924         done
 925         ;;
 926 (*)
 927         AC_MSG_RESULT(ok)
 928         ;;
 929 esac
 930
 931 AC_MSG_CHECKING(\$CC variable)
 932 case "$CC" in
 933 (*[[\ \ ]]-*)
 934         AC_MSG_RESULT(broken)
 935         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 936         # humor him...
 937         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 938         cf_flags=`echo "$CC" | sed -e "s%^$cf_prog%%"`
 939         CC="$cf_prog"
 940         for cf_arg in $cf_flags
 941         do
 942                 case "x$cf_arg" in
 943                 (x-[[IUDfgOW]]*)
 944                         CF_ADD_CFLAGS($cf_arg)
 945                         ;;
 946                 (*)
 947                         CC="$CC $cf_arg"
 948                         ;;
 949                 esac
 950         done
 951         CF_VERBOSE(resulting CC: '$CC')
 952         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 953         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 954         ;;
 955 (*)
 956         AC_MSG_RESULT(ok)
 957         ;;
 958 esac
 959 ])dnl
 960 dnl ---------------------------------------------------------------------------
 961 dnl CF_CFG_DEFAULTS version: 16 updated: 2021/01/04 19:33:05
 962 dnl ---------------
 963 dnl Determine the default configuration into which we'll install ncurses.  This
 964 dnl can be overridden by the user's command-line options.  There's two items to
 965 dnl look for:
 966 dnl     1. the prefix (e.g., /usr)
 967 dnl     2. the header files (e.g., /usr/include/ncurses)
 968 dnl We'll look for a previous installation of ncurses and use the same defaults.
 969 dnl
 970 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 971 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 972 dnl programs from a vendor's.
 973 AC_DEFUN([CF_CFG_DEFAULTS],
 974 [AC_REQUIRE([AC_PROG_FGREP])dnl
 975
 976 AC_MSG_CHECKING(for prefix)
 977 if test "x$prefix" = "xNONE" ; then
 978         case "$cf_cv_system_name" in
 979                 # non-vendor systems don't have a conflict
 980         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 981                 prefix=/usr
 982                 ;;
 983         (*)     prefix=$ac_default_prefix
 984                 ;;
 985         esac
 986 fi
 987 AC_MSG_RESULT($prefix)
 988
 989 if test "x$prefix" = "xNONE" ; then
 990 AC_MSG_CHECKING(for default include-directory)
 991 test -n "$verbose" && echo 1>&AC_FD_MSG
 992 for cf_symbol in \
 993         "$includedir" \
 994         "$includedir/ncurses" \
 995         "$prefix/include" \
 996         "$prefix/include/ncurses" \
 997         /usr/local/include \
 998         /usr/local/include/ncurses \
 999         /usr/include \
1000         /usr/include/ncurses
1001 do
1002         cf_dir=`eval echo "$cf_symbol"`
1003         if test -f "$cf_dir/curses.h" ; then
1004         if ( ${FGREP-fgrep} NCURSES_VERSION "$cf_dir/curses.h" >/dev/null 2>&1 ) ; then
1005                 includedir="$cf_symbol"
1006                 test -n "$verbose"  && echo $ECHO_N "   found " 1>&AC_FD_MSG
1007                 break
1008         fi
1009         fi
1010         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
1011 done
1012 AC_MSG_RESULT($includedir)
1013 fi
1014 ])dnl
1015 dnl ---------------------------------------------------------------------------
1016 dnl CF_CGETENT version: 7 updated: 2023/02/18 17:41:25
1017 dnl ----------
1018 dnl Check if the terminal-capability database functions are available.  If not,
1019 dnl ncurses has a much-reduced version.
1020 AC_DEFUN([CF_CGETENT],[
1021 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
1022 AC_TRY_LINK([
1023 $ac_includes_default],[
1024         char temp[128];
1025         char *buf = temp;
1026         char *db_array = temp;
1027         cgetent(&buf, &db_array, "vt100");
1028         cgetcap(buf, "tc", '=');
1029         cgetmatch(buf, "tc");
1030         ],
1031         [cf_cv_cgetent=yes],
1032         [cf_cv_cgetent=no])
1033 ])
1034
1035 if test "$cf_cv_cgetent" = yes
1036 then
1037         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
1038 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
1039 AC_TRY_LINK([
1040 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
1041 $ac_includes_default],[
1042         char temp[128];
1043         char *buf = temp;
1044 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
1045         const char *db_array = temp;
1046         cgetent(&buf, &db_array, "vt100");
1047 #endif
1048         cgetcap(buf, "tc", '=');
1049         cgetmatch(buf, "tc");
1050         ],
1051         [cf_cv_cgetent_const=yes],
1052         [cf_cv_cgetent_const=no])
1053 ])
1054         if test "$cf_cv_cgetent_const" = yes
1055         then
1056                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
1057         fi
1058 fi
1059 ])dnl
1060 dnl ---------------------------------------------------------------------------
1061 dnl CF_CHECK_CACHE version: 13 updated: 2020/12/31 10:54:15
1062 dnl --------------
1063 dnl Check if we're accidentally using a cache from a different machine.
1064 dnl Derive the system name, as a check for reusing the autoconf cache.
1065 dnl
1066 dnl If we've packaged config.guess and config.sub, run that (since it does a
1067 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
1068 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
1069 dnl which is useful in cross-compiles.
1070 dnl
1071 dnl Note: we would use $ac_config_sub, but that is one of the places where
1072 dnl autoconf 2.5x broke compatibility with autoconf 2.13
1073 AC_DEFUN([CF_CHECK_CACHE],
1074 [
1075 if test -f "$srcdir/config.guess" || test -f "$ac_aux_dir/config.guess" ; then
1076         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
1077         system_name="$host_os"
1078 else
1079         system_name="`(uname -s -r) 2>/dev/null`"
1080         if test -z "$system_name" ; then
1081                 system_name="`(hostname) 2>/dev/null`"
1082         fi
1083 fi
1084 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
1085 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
1086
1087 test -z "$system_name" && system_name="$cf_cv_system_name"
1088 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
1089
1090 if test ".$system_name" != ".$cf_cv_system_name" ; then
1091         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
1092         AC_MSG_ERROR("Please remove config.cache and try again.")
1093 fi
1094 ])dnl
1095 dnl ---------------------------------------------------------------------------
1096 dnl CF_CHECK_ENVIRON version: 5 updated: 2023/02/18 17:41:25
1097 dnl ----------------
1098 dnl Check for data that is usually declared in <unistd.h>, e.g., the 'environ'
1099 dnl variable.  Define a DECL_xxx symbol if we must declare it ourselves.
1100 dnl
1101 dnl $1 = the name to check
1102 dnl $2 = the assumed type
1103 AC_DEFUN([CF_CHECK_ENVIRON],
1104 [
1105 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1106     AC_TRY_COMPILE([
1107 $ac_includes_default],
1108     ifelse([$2],,void*,[$2]) x = (ifelse([$2],,void*,[$2])) $1; (void)x,
1109     [cf_cv_dcl_$1=yes],
1110     [cf_cv_dcl_$1=no])
1111 ])
1112
1113 if test "$cf_cv_dcl_$1" = no ; then
1114     CF_UPPER(cf_result,decl_$1)
1115     AC_DEFINE_UNQUOTED($cf_result)
1116 fi
1117
1118 # It's possible (for near-UNIX clones) that the data doesn't exist
1119 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1120 ])dnl
1121 dnl ---------------------------------------------------------------------------
1122 dnl CF_CHECK_ERRNO version: 14 updated: 2023/02/18 17:41:25
1123 dnl --------------
1124 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
1125 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
1126 dnl ourselves.
1127 dnl
1128 dnl $1 = the name to check
1129 dnl $2 = the assumed type
1130 AC_DEFUN([CF_CHECK_ERRNO],
1131 [
1132 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1133         AC_TRY_COMPILE([
1134 $ac_includes_default
1135 #include <errno.h> ],
1136         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1; (void)x,
1137         [cf_cv_dcl_$1=yes],
1138         [cf_cv_dcl_$1=no])
1139 ])
1140
1141 if test "$cf_cv_dcl_$1" = no ; then
1142         CF_UPPER(cf_result,decl_$1)
1143         AC_DEFINE_UNQUOTED($cf_result)
1144 fi
1145
1146 # It's possible (for near-UNIX clones) that the data doesn't exist
1147 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1148 ])dnl
1149 dnl ---------------------------------------------------------------------------
1150 dnl CF_CHECK_EXTERN_DATA version: 5 updated: 2021/09/04 06:35:04
1151 dnl --------------------
1152 dnl Check for existence of external data in the current set of libraries.  If
1153 dnl we can modify it, it is real enough.
1154 dnl $1 = the name to check
1155 dnl $2 = its type
1156 AC_DEFUN([CF_CHECK_EXTERN_DATA],
1157 [
1158 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
1159         AC_TRY_LINK([
1160 #undef $1
1161 extern $2 $1;
1162 ],
1163         [$1 = 2],
1164         [cf_cv_have_$1=yes],
1165         [cf_cv_have_$1=no])
1166 ])
1167
1168 if test "$cf_cv_have_$1" = yes ; then
1169         CF_UPPER(cf_result,have_$1)
1170         AC_DEFINE_UNQUOTED($cf_result)
1171 fi
1172
1173 ])dnl
1174 dnl ---------------------------------------------------------------------------
1175 dnl CF_CHECK_FVISIBILITY version: 2 updated: 2020/04/04 16:16:13
1176 dnl --------------------
1177 dnl Check whether the compiler understands -fvisibility=hidden
1178 dnl
1179 dnl $1 = compiler
1180 dnl $2 = compiler-flags variable name
1181 dnl $3 = cache variable to set
1182 AC_DEFUN([CF_CHECK_FVISIBILITY],[
1183 AC_CACHE_CHECK(if $1 -fvisibility=hidden option works,$3,[
1184     cf_save_cflags="[$]$2"
1185     $2="[$]$2 -fvisibility=hidden"
1186     AC_TRY_LINK([
1187 __attribute__ ((visibility("default"))) int somefunc() {return 42;}
1188         ],[
1189         if (somefunc()) return 1;
1190 ],
1191     [$3=yes],
1192     [$3=no])
1193     $2=$cf_save_cflags
1194 ])
1195 ])dnl
1196 dnl ---------------------------------------------------------------------------
1197 dnl CF_CHECK_GETENV version: 3 updated: 2023/01/05 17:47:56
1198 dnl ---------------
1199 dnl Check if repeated getenv calls return the same pointer, e.g., it does not
1200 dnl discard the previous pointer when returning a new one.
1201 AC_DEFUN([CF_CHECK_GETENV],
1202 [
1203 AC_REQUIRE([CF_CHECK_ENVIRON])
1204 AC_CHECK_FUNC( getenv, ,, AC_MSG_ERROR(getenv not found) )
1205 AC_CHECK_FUNCS( putenv setenv strdup )
1206 AC_CACHE_CHECK(if getenv returns consistent values,cf_cv_consistent_getenv,[
1207 AC_TRY_RUN([
1208 $ac_includes_default
1209
1210 #if defined(HAVE_ENVIRON) && defined(DECL_ENVIRON) && !defined(environ)
1211 extern char **environ;  /* POSIX, but some systems are not... */
1212 #endif
1213
1214 #if defined(HAVE_STRDUP)
1215 #define str_alloc(s) strdup(s)
1216 #else
1217 #define str_alloc(s) strcpy(malloc(strlen(s) + 1, s))
1218 #endif
1219
1220 static void set_value(const char *name, const char *value)
1221 {
1222 #if defined(HAVE_SETENV)
1223         setenv(name, value, 1);
1224 #elif defined(HAVE_PUTENV)
1225         char buffer[1024];
1226         sprintf(buffer, "%s=%s", name, value);
1227         putenv(str_alloc(buffer));
1228 #else
1229 #error neither putenv/setenv found
1230 #endif
1231 }
1232 int main(void)
1233 {
1234         int pass;
1235         size_t numenv, limit, j;
1236         char **mynames;
1237         char **myvalues;
1238         char **mypointer;
1239         char *equals;
1240         for (numenv = 0; environ[numenv]; ++numenv) ;
1241         limit = numenv + 10;
1242         mynames = (char **) calloc(limit + 1, sizeof(char *));
1243         myvalues = (char **) calloc(limit + 1, sizeof(char *));
1244         mypointer = (char **) calloc(limit + 1, sizeof(char *));
1245 #if defined(HAVE_ENVIRON)
1246         for (j = 0; environ[j]; ++j) {
1247                 mynames[j] = str_alloc(environ[j]);
1248                 equals = strchr(mynames[j], '=');
1249                 if (equals != 0) {
1250                         *equals++ = '\\0';
1251                         myvalues[j] = str_alloc(equals);
1252                 } else {
1253                         myvalues[j] = str_alloc("");
1254                 }
1255         }
1256 #endif
1257         for (j = numenv; j < limit; ++j) {
1258                 char name[80];
1259                 char value[80];
1260                 size_t found;
1261                 size_t k = 0;
1262                 do {
1263                         size_t jk;
1264                         found = 0;
1265                         sprintf(name, "TERM%lu", (unsigned long) k);
1266                         for (jk = 0; jk < j; ++jk) {
1267                                 if (!strcmp(name, mynames[jk])) {
1268                                         found = 1;
1269                                         ++k;
1270                                         break;
1271                                 }
1272                         }
1273                 } while (found);
1274                 sprintf(value, "%lu:%p", (unsigned long) k, &mynames[j]);
1275                 set_value(name, value);
1276                 mynames[j] = str_alloc(name);
1277                 myvalues[j] = str_alloc(value);
1278         }
1279         for (pass = 0; pass < 3; ++pass) {
1280                 for (j = 0; j < limit; ++j) {
1281                         char *value = getenv(mynames[j]);
1282                         if (pass) {
1283                                 if (value == 0) {
1284                                         fprintf(stderr, "getenv returned null for %s\\n", mynames[j]);
1285                                         ${cf_cv_main_return:-return}(1);
1286                                 } else if (value != mypointer[j]) {
1287                                         fprintf(stderr, "getenv returned different pointer for %s\\n", mynames[j]);
1288                                         ${cf_cv_main_return:-return}(1);
1289                                 } else if (strcmp(value, myvalues[j])) {
1290                                         fprintf(stderr, "getenv returned different value for %s\\n", mynames[j]);
1291                                         ${cf_cv_main_return:-return}(1);
1292                                 }
1293                         } else {
1294                                 size_t k;
1295                                 mypointer[j] = value;
1296                                 for (k = 0; k < j; ++k) {
1297                                         if (mypointer[j] == mypointer[k]) {
1298                                                 fprintf(stderr, "getenv returned same pointer for %s and %s\\n", mynames[j], mynames[k]);
1299                                                 ${cf_cv_main_return:-return}(1);
1300                                         }
1301                                 }
1302                         }
1303                 }
1304         }
1305         ${cf_cv_main_return:-return}(0);
1306 }
1307 ],
1308 [cf_cv_consistent_getenv=yes],
1309 [cf_cv_consistent_getenv=no],
1310 [cf_cv_consistent_getenv=unknown])
1311 ])
1312
1313 if test "x$cf_cv_consistent_getenv" = xno
1314 then
1315         AC_DEFINE(HAVE_CONSISTENT_GETENV,1,[Define to 1 if getenv repeatably returns the same value for a given name])
1316 fi
1317 ])dnl
1318 dnl ---------------------------------------------------------------------------
1319 dnl CF_CHECK_GNAT_VERSION version: 4 updated: 2021/01/01 13:31:04
1320 dnl ---------------------
1321 AC_DEFUN([CF_CHECK_GNAT_VERSION],
1322 [
1323 AC_REQUIRE([CF_GNAT_VERSION])
1324 case "$cf_cv_gnat_version" in
1325 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
1326         cf_cv_prog_gnat_correct=yes
1327         ;;
1328 (*)
1329         AC_MSG_WARN(Unsupported GNAT version $cf_cv_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1330         cf_cv_prog_gnat_correct=no
1331         ;;
1332 esac
1333 ])
1334 dnl ---------------------------------------------------------------------------
1335 dnl CF_CHECK_GPM_WGETCH version: 6 updated: 2021/01/04 18:48:01
1336 dnl -------------------
1337 dnl Check if GPM is already linked with curses.  If so - and if the linkage
1338 dnl is not "weak" - warn about this because it can create problems linking
1339 dnl applications with ncurses.
1340 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
1341 AC_REQUIRE([AC_PROG_EGREP])dnl
1342
1343 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
1344
1345 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
1346 cf_cv_check_gpm_wgetch=unknown
1347 if test "$cross_compiling" != yes ; then
1348
1349 cat >conftest.$ac_ext <<CF_EOF
1350 #include <gpm.h>
1351 int main(void)
1352 {
1353         Gpm_Wgetch();
1354         ${cf_cv_main_return:-return}(0);
1355 }
1356 CF_EOF
1357
1358         cf_save_LIBS="$LIBS"
1359         # This only works if we can look at the symbol table.  If a shared
1360         # library is stripped for install, we cannot use that.  So we're forced
1361         # to rely on the static library, noting that some packagers may not
1362         # include it.
1363         LIBS="-static -lgpm -dynamic $LIBS"
1364         if AC_TRY_EVAL(ac_compile) ; then
1365                 if AC_TRY_EVAL(ac_link) ; then
1366                         cf_cv_check_gpm_wgetch="`nm \"conftest$ac_exeext\" | ${EGREP-egrep} '\<wgetch\>' | ${EGREP-egrep} '\<[[vVwW]]\>'`"
1367                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
1368                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
1369                 fi
1370         fi
1371         rm -rf ./conftest*
1372         LIBS="$cf_save_LIBS"
1373 fi
1374 ])
1375
1376 if test "$cf_cv_check_gpm_wgetch" != yes ; then
1377         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
1378 fi
1379 ])])dnl
1380 dnl ---------------------------------------------------------------------------
1381 dnl CF_CHECK_LIBSSP version: 1 updated: 2021/10/30 10:40:19
1382 dnl ---------------
1383 dnl Check if libssp is needed, e.g., to work around misconfigured libraries
1384 dnl used in cross-compiling to MinGW.
1385 AC_DEFUN([CF_CHECK_LIBSSP],[
1386 AC_CACHE_CHECK(if ssp library is needed,cf_cv_need_libssp,[
1387 AC_TRY_LINK([
1388 #include <sys/types.h>
1389 #include <dirent.h>
1390 ],[
1391        DIR *dp = opendir(".");
1392 ],cf_cv_need_libssp=no,[
1393         cf_save_LIBS="$LIBS"
1394         LIBS="$LIBS -lssp"
1395         AC_TRY_LINK([
1396 #include <sys/types.h>
1397 #include <dirent.h>
1398         ],[
1399                    DIR *dp = opendir(".");
1400         ],cf_cv_need_libssp=yes,
1401           cf_cv_need_libssp=maybe)
1402         LIBS="$cf_save_LIBS"
1403 ])dnl
1404 ])
1405
1406 if test "x$cf_cv_need_libssp" = xyes
1407 then
1408         CF_ADD_LIB(ssp)
1409 fi
1410 ])dnl
1411 dnl ---------------------------------------------------------------------------
1412 dnl CF_CHECK_LIBTOOL_VERSION version: 2 updated: 2021/05/01 16:24:34
1413 dnl ------------------------
1414 dnl Show the version of libtool
1415 dnl
1416 dnl Save the version in a cache variable - this is not entirely a good thing,
1417 dnl but the version string from libtool is very ugly, and for bug reports it
1418 dnl might be useful to have the original string.
1419 dnl
1420 dnl There is an imitation in OpenBSD, which has no apparent use other than to
1421 dnl deny that it is GNU libtool.  Just ignore it.
1422 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1423 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1424 then
1425         AC_MSG_CHECKING(version of $LIBTOOL)
1426         CF_LIBTOOL_VERSION
1427         AC_MSG_RESULT($cf_cv_libtool_version)
1428         if test -n "$cf_cv_libtool_version"
1429         then
1430                 cf_check_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' -e 's,[[()]],...,g' -e 's,[[ ]],-,g' -e '2,$d'`
1431                 case "x$cf_check_libtool_version" in
1432                 (*...GNU-libtool...*)
1433                         ;;
1434                 (*)
1435                         AC_MSG_ERROR(This is not GNU libtool)
1436                         ;;
1437                 esac
1438         else
1439                 AC_MSG_ERROR(No version found for $LIBTOOL)
1440         fi
1441 else
1442         AC_MSG_ERROR(GNU libtool has not been found)
1443 fi
1444 ])dnl
1445 dnl ---------------------------------------------------------------------------
1446 dnl CF_CHECK_WCHAR_H version: 4 updated: 2023/02/18 17:41:25
1447 dnl ----------------
1448 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1449 AC_DEFUN([CF_CHECK_WCHAR_H],[
1450 AC_CHECK_HEADERS( \
1451 wchar.h \
1452 wctype.h \
1453 )
1454 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1455 AC_TRY_COMPILE(
1456 [
1457 $ac_includes_default
1458 #ifdef HAVE_WCHAR_H
1459 #include <wchar.h>
1460 #endif
1461 #ifdef HAVE_WCTYPE_H
1462 #include <wctype.h>
1463 #endif
1464 ],[
1465         wint_t foo = 0;
1466         int bar = iswpunct(foo)],
1467         [cf_cv_wchar_h_okay=yes],
1468         [cf_cv_wchar_h_okay=no])])
1469
1470 if test "$cf_cv_wchar_h_okay" = no
1471 then
1472         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1473 fi
1474 ])dnl
1475 dnl ---------------------------------------------------------------------------
1476 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 3 updated: 2023/01/05 18:01:30
1477 dnl -------------------------
1478 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1479 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1480 dnl
1481 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1482 dnl all of those were combined into a page of useful graphics characters.
1483 dnl
1484 dnl So far, so good.
1485 dnl
1486 dnl However, while they are useful, there are other considerations.  CJK
1487 dnl is (because of poor device resolution) often rendered as double-width
1488 dnl characters.  So... for these generally-useful characters, what should
1489 dnl be the width (to make them consistent with adjacent characters)?
1490 dnl
1491 dnl The obvious choice would have been to make this locale-dependent, and use
1492 dnl wcwidth() to tell applications what the actual width is.  That was too
1493 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1494 dnl See for example
1495 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1496 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1497 dnl
1498 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1499 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1500 dnl instance, it lists half (44/96) of the Latin-1 characters as
1501 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1502 dnl
1503 dnl What this means for the implementor is that on some systems wcwidth() can
1504 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1505 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1506 dnl characters).  These do not necessarily match the behavior of the terminal
1507 dnl emulator.  xterm, for instance, does an optional startup check to find if
1508 dnl this problem (or similar) exists with the system's locale tables, rejecting
1509 dnl them if they are too unreliable.
1510 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1511 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1512 cat >conftest.in <<CF_EOF
1513 -       VT100 symbols
1514 0x250c  upper left corner
1515 0x2514  lower left corner
1516 0x2510  upper right corner
1517 0x2518  lower right corner
1518 0x251c  tee pointing left
1519 0x2524  tee pointing right
1520 0x2534  tee pointing up
1521 0x252c  tee pointing down
1522 0x2500  horizontal line
1523 0x2502  vertical line
1524 0x253c  large plus or crossover
1525 0x23ba  scan line 1
1526 0x23bd  scan line 9
1527 0x25c6  diamond
1528 0x2592  checker board (stipple)
1529 0x00b0  degree symbol
1530 0x00b1  plus/minus
1531 0x00b7  bullet
1532 -       Teletype 5410v1 symbols
1533 0x2190  arrow pointing left
1534 0x2192  arrow pointing right
1535 0x2193  arrow pointing down
1536 0x2191  arrow pointing up
1537 0x2592  board of squares
1538 0x2603  lantern symbol
1539 0x25ae  solid square block
1540 -       these defaults were invented for ncurses
1541 0x23bb  scan line 3
1542 0x23bc  scan line 7
1543 0x2264  less-than-or-equal-to
1544 0x2265  greater-than-or-equal-to
1545 0x03c0  greek pi
1546 0x2260  not-equal
1547 0x00a3  pound-sterling symbol
1548 -       thick-line-drawing
1549 0x250f  upper left corner
1550 0x2517  lower left corner
1551 0x2513  upper right corner
1552 0x251b  lower right corner
1553 0x2523  tee pointing left
1554 0x252b  tee pointing right
1555 0x253b  tee pointing up
1556 0x2533  tee pointing down
1557 0x2501  horizontal line
1558 0x2503  vertical line
1559 0x254b  large plus or crossover
1560 -       double-line-drawing
1561 0x2554  upper left corner
1562 0x255a  lower left corner
1563 0x2557  upper right corner
1564 0x255d  lower right corner
1565 0x2563  tee pointing left
1566 0x2560  tee pointing right
1567 0x2569  tee pointing up
1568 0x2566  tee pointing down
1569 0x2550  horizontal line
1570 0x2551  vertical line
1571 0x256c  large plus or crossover
1572 CF_EOF
1573 AC_TRY_RUN([
1574 $ac_includes_default
1575
1576 #include <locale.h>
1577 #include <wchar.h>
1578
1579 #define MY_LEN 80
1580
1581 int
1582 main(void)
1583 {
1584         FILE *fp;
1585         int value;
1586         char buffer[MY_LEN + 1];
1587         char notes[MY_LEN + 1];
1588         int totals = 0;
1589         int passed = 0;
1590
1591         if (setlocale(LC_ALL, "en_US.UTF8") ||
1592                 setlocale(LC_ALL, "en_US.UTF-8") ||
1593                 setlocale(LC_ALL, "en_US.utf8") ||
1594                 setlocale(LC_ALL, "en_US.utf-8")) {
1595                 if ((fp = fopen("conftest.in", "r")) != 0) {
1596                         while (fgets(buffer, MY_LEN, fp) != 0) {
1597                                 if (*buffer == '-') {
1598                                         fprintf(stderr, "\\t%s", buffer);
1599                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1600                                         ++totals;
1601                                         if (wcwidth(value) == 1)
1602                                                 ++passed;
1603                                         fprintf(stderr, "%d\\t%s", wcwidth(value), buffer);
1604                                 } else {
1605                                         fprintf(stderr, "?\\t%s", buffer);
1606                                 }
1607                         }
1608                 }
1609         }
1610         fprintf(stderr, "%d/%d passed wcwidth/graphics check\\n", passed, totals);
1611         return (totals == passed) ? 0 : 1;
1612 }
1613 ],
1614 [cf_cv_wcwidth_graphics=yes],
1615 [cf_cv_wcwidth_graphics=no],
1616 [cf_cv_wcwidth_graphics=unknown])
1617 ])
1618 ])dnl
1619 dnl ---------------------------------------------------------------------------
1620 dnl CF_CLANG_COMPILER version: 9 updated: 2023/02/18 17:41:25
1621 dnl -----------------
1622 dnl Check if the given compiler is really clang.  clang's C driver defines
1623 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1624 dnl not ignore some gcc options.
1625 dnl
1626 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1627 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1628 dnl the wrappers for gcc and g++ warnings.
1629 dnl
1630 dnl $1 = GCC (default) or GXX
1631 dnl $2 = CLANG_COMPILER (default)
1632 dnl $3 = CFLAGS (default) or CXXFLAGS
1633 AC_DEFUN([CF_CLANG_COMPILER],[
1634 ifelse([$2],,CLANG_COMPILER,[$2])=no
1635
1636 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1637         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1638         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1639         AC_TRY_COMPILE([],[
1640 #ifdef __clang__
1641 #else
1642 #error __clang__ is not defined
1643 #endif
1644 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1645 ],[])
1646         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1647         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1648 fi
1649
1650 CLANG_VERSION=none
1651
1652 if test "x$ifelse([$2],,CLANG_COMPILER,[$2])" = "xyes" ; then
1653         case "$CC" in
1654         (c[[1-9]][[0-9]]|*/c[[1-9]][[0-9]])
1655                 AC_MSG_WARN(replacing broken compiler alias $CC)
1656                 CFLAGS="$CFLAGS -std=`echo "$CC" | sed -e 's%.*/%%'`"
1657                 CC=clang
1658                 ;;
1659         esac
1660
1661         AC_MSG_CHECKING(version of $CC)
1662         CLANG_VERSION="`$CC --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(CLANG[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1663         test -z "$CLANG_VERSION" && CLANG_VERSION=unknown
1664         AC_MSG_RESULT($CLANG_VERSION)
1665
1666         for cf_clang_opt in \
1667                 -Qunused-arguments \
1668                 -Wno-error=implicit-function-declaration
1669         do
1670                 AC_MSG_CHECKING(if option $cf_clang_opt works)
1671                 cf_save_CFLAGS="$CFLAGS"
1672                 CFLAGS="$CFLAGS $cf_clang_opt"
1673                 AC_TRY_LINK([
1674                         #include <stdio.h>],[
1675                         printf("hello!\\n");],[
1676                         cf_clang_optok=yes],[
1677                         cf_clang_optok=no])
1678                 AC_MSG_RESULT($cf_clang_optok)
1679                 CFLAGS="$cf_save_CFLAGS"
1680                 if test "$cf_clang_optok" = yes; then
1681                         CF_VERBOSE(adding option $cf_clang_opt)
1682                         CF_APPEND_TEXT(CFLAGS,$cf_clang_opt)
1683                 fi
1684         done
1685 fi
1686 ])
1687 dnl ---------------------------------------------------------------------------
1688 dnl CF_CONST_X_STRING version: 7 updated: 2021/06/07 17:39:17
1689 dnl -----------------
1690 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
1691 dnl character-strings.
1692 dnl
1693 dnl It is ambiguous because the specification accommodated the pre-ANSI
1694 dnl compilers bundled by more than one vendor in lieu of providing a standard C
1695 dnl compiler other than by costly add-ons.  Because of this, the specification
1696 dnl did not take into account the use of const for telling the compiler that
1697 dnl string literals would be in readonly memory.
1698 dnl
1699 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
1700 dnl let the compiler decide how to represent Xt's strings which were #define'd.
1701 dnl That does not solve the problem of using the block of Xt's strings which
1702 dnl are compiled into the library (and is less efficient than one might want).
1703 dnl
1704 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
1705 dnl when compiling the library and compiling using the library, to tell the
1706 dnl compiler that String is const.
1707 AC_DEFUN([CF_CONST_X_STRING],
1708 [
1709 AC_REQUIRE([AC_PATH_XTRA])
1710
1711 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
1712
1713 AC_TRY_COMPILE(
1714 [
1715 #include <stdlib.h>
1716 #include <X11/Intrinsic.h>
1717 ],
1718 [String foo = malloc(1); free((void*)foo)],[
1719
1720 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
1721         AC_TRY_COMPILE(
1722                 [
1723 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
1724 #undef  XTSTRINGDEFINES /* X11R5 and later */
1725 #include <stdlib.h>
1726 #include <X11/Intrinsic.h>
1727                 ],[String foo = malloc(1); *foo = 0],[
1728                         cf_cv_const_x_string=no
1729                 ],[
1730                         cf_cv_const_x_string=yes
1731                 ])
1732 ])
1733
1734 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
1735
1736 case "$cf_cv_const_x_string" in
1737 (no)
1738         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
1739         ;;
1740 (*)
1741         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
1742         ;;
1743 esac
1744
1745 ])
1746 ])dnl
1747 dnl ---------------------------------------------------------------------------
1748 dnl CF_CPP_OVERRIDE version: 1 updated: 2022/08/20 16:07:10
1749 dnl ---------------
1750 dnl Check if the C++ compiler accepts the override keyword.  This is a C++-11
1751 dnl feature.
1752 AC_DEFUN([CF_CPP_OVERRIDE],
1753 [
1754 if test -n "$CXX"; then
1755 AC_CACHE_CHECK(if $CXX accepts override keyword,cf_cv_cpp_override,[
1756         AC_LANG_SAVE
1757         AC_LANG_CPLUSPLUS
1758         AC_TRY_RUN([
1759
1760 class base
1761 {
1762 public:
1763         virtual int foo(float x) = 0;
1764 };
1765
1766
1767 class derived: public base
1768 {
1769 public:
1770         int foo(float x) override { return x != 0.0 ? 1 : 0; }
1771 };
1772
1773 int main(void) { }
1774 ],
1775         [cf_cv_cpp_override=yes],
1776         [cf_cv_cpp_override=no],
1777         [cf_cv_cpp_override=unknown])
1778         AC_LANG_RESTORE
1779 ])
1780 fi
1781 test "$cf_cv_cpp_override" = yes && AC_DEFINE(CPP_HAS_OVERRIDE,1,[Define to 1 if C++ has override keyword])
1782 ])dnl
1783 dnl ---------------------------------------------------------------------------
1784 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1785 dnl -----------------
1786 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1787 dnl is a late feature for the standard and is not in some recent compilers
1788 dnl (1999/9/11).
1789 AC_DEFUN([CF_CPP_PARAM_INIT],
1790 [
1791 if test -n "$CXX"; then
1792 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1793         AC_LANG_SAVE
1794         AC_LANG_CPLUSPLUS
1795         AC_TRY_RUN([
1796 class TEST {
1797 private:
1798         int value;
1799 public:
1800         TEST(int x = 1);
1801         ~TEST();
1802 };
1803
1804 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1805 {
1806         value = x;
1807 }
1808 int main(void) { }
1809 ],
1810         [cf_cv_cpp_param_init=yes],
1811         [cf_cv_cpp_param_init=no],
1812         [cf_cv_cpp_param_init=unknown])
1813         AC_LANG_RESTORE
1814 ])
1815 fi
1816 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1817 ])dnl
1818 dnl ---------------------------------------------------------------------------
1819 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1820 dnl ------------------
1821 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1822 dnl not be supported in g++ before 3.0
1823 AC_DEFUN([CF_CPP_STATIC_CAST],
1824 [
1825 if test -n "$CXX"; then
1826
1827 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1828         AC_LANG_SAVE
1829         AC_LANG_CPLUSPLUS
1830
1831         AC_TRY_COMPILE([
1832 class NCursesPanel
1833 {
1834 public:
1835   NCursesPanel(int nlines,
1836                int ncols,
1837                int begin_y = 0,
1838                int begin_x = 0)
1839   {
1840   }
1841   NCursesPanel();
1842   ~NCursesPanel();
1843 };
1844
1845 template<class T> class NCursesUserPanel : public NCursesPanel
1846 {
1847 public:
1848   NCursesUserPanel (int nlines,
1849                     int ncols,
1850                     int begin_y = 0,
1851                     int begin_x = 0,
1852                     const T* p_UserData = static_cast<T*>(0))
1853     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1854   {
1855   };
1856   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1857   {
1858   };
1859
1860   virtual ~NCursesUserPanel() {};
1861 };
1862 ],[
1863         const char* p_UserData = static_cast<char*>(0)],
1864         [cf_cv_cpp_static_cast=yes],
1865         [cf_cv_cpp_static_cast=no])
1866
1867         AC_LANG_RESTORE
1868 ])
1869
1870 fi
1871
1872 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1873 ])dnl
1874 dnl ---------------------------------------------------------------------------
1875 dnl CF_CXX_AR_FLAGS version: 3 updated: 2021/01/01 13:31:04
1876 dnl ---------------
1877 dnl Setup special archiver flags for given compilers.
1878 AC_DEFUN([CF_CXX_AR_FLAGS],[
1879         CXX_AR='$(AR)'
1880         CXX_ARFLAGS='$(ARFLAGS)'
1881         case "$cf_cv_system_name" in
1882         (irix*)
1883             if test "$GXX" != yes ; then
1884                 CXX_AR='$(CXX)'
1885                 CXX_ARFLAGS='-ar -o'
1886             fi
1887             ;;
1888         (sco3.2v5*)
1889             CXXLDFLAGS="-u main"
1890             ;;
1891         (solaris2*)
1892             if test "$GXX" != yes ; then
1893                 CXX_AR='$(CXX)'
1894                 CXX_ARFLAGS='-xar -o'
1895             fi
1896             ;;
1897         esac
1898         AC_SUBST(CXXLDFLAGS)
1899         AC_SUBST(CXX_AR)
1900         AC_SUBST(CXX_ARFLAGS)
1901 ])dnl
1902 dnl ---------------------------------------------------------------------------
1903 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1904 dnl -------------------------
1905 dnl For c++, check if iostream uses "std::" namespace.
1906 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1907 AC_CHECK_HEADERS(iostream)
1908 if test x"$ac_cv_header_iostream" = xyes ; then
1909         AC_MSG_CHECKING(if iostream uses std-namespace)
1910         AC_TRY_COMPILE([
1911 #include <iostream>
1912 using std::endl;
1913 using std::cerr;],[
1914 cerr << "testing" << endl;
1915 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1916         AC_MSG_RESULT($cf_iostream_namespace)
1917         if test "$cf_iostream_namespace" = yes ; then
1918                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1919         fi
1920 fi
1921 ])dnl
1922 dnl ---------------------------------------------------------------------------
1923 dnl CF_C_INLINE version: 6 updated: 2019/09/07 13:38:36
1924 dnl -----------
1925 dnl Check if the C compiler supports "inline".
1926 dnl $1 is the name of a shell variable to set if inline is supported
1927 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1928 AC_DEFUN([CF_C_INLINE],[
1929 AC_REQUIRE([CF_GCC_VERSION])
1930 AC_C_INLINE
1931 $1=
1932 if test "$ac_cv_c_inline" != no ; then
1933         $1=inline
1934         if test "$INTEL_COMPILER" = yes
1935         then
1936                 :
1937         elif test "$CLANG_COMPILER" = yes
1938         then
1939                 :
1940         elif test "$GCC" = yes
1941         then
1942                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1943                 cf_save_CFLAGS=$CFLAGS
1944                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1945                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1946                 [${cf_cv_main_return:-return} foo()],
1947                 [cf_cv_gcc_inline=yes],
1948                 [cf_cv_gcc_inline=no])
1949                 CFLAGS=$cf_save_CFLAGS
1950                 ])
1951                 if test "$cf_cv_gcc_inline" = yes ; then
1952                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1953                 fi
1954         fi
1955 fi
1956 AC_SUBST($1)
1957 ])dnl
1958 dnl ---------------------------------------------------------------------------
1959 dnl CF_DIRNAME version: 5 updated: 2020/12/31 20:19:42
1960 dnl ----------
1961 dnl "dirname" is not portable, so we fake it with a shell script.
1962 AC_DEFUN([CF_DIRNAME],[$1=`echo "$2" | sed -e 's%/[[^/]]*$%%'`])dnl
1963 dnl ---------------------------------------------------------------------------
1964 dnl CF_DIRS_TO_MAKE version: 4 updated: 2021/01/01 13:31:04
1965 dnl ---------------
1966 AC_DEFUN([CF_DIRS_TO_MAKE],
1967 [
1968 DIRS_TO_MAKE="lib"
1969 for cf_item in $cf_list_models
1970 do
1971         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1972         for cf_item2 in $DIRS_TO_MAKE
1973         do
1974                 test "$cf_item2" = "$cf_subdir" && break
1975         done
1976         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1977 done
1978 for cf_dir in $DIRS_TO_MAKE
1979 do
1980         test ! -d "$cf_dir" && mkdir "$cf_dir"
1981 done
1982 AC_SUBST(DIRS_TO_MAKE)
1983 ])dnl
1984 dnl ---------------------------------------------------------------------------
1985 dnl CF_DISABLE_ECHO version: 14 updated: 2021/09/04 06:35:04
1986 dnl ---------------
1987 dnl You can always use "make -n" to see the actual options, but it is hard to
1988 dnl pick out/analyze warning messages when the compile-line is long.
1989 dnl
1990 dnl Sets:
1991 dnl     ECHO_LT - symbol to control if libtool is verbose
1992 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1993 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1994 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1995 dnl     ECHO_CC - symbol to put before any "cc" line
1996 dnl
1997 AC_DEFUN([CF_DISABLE_ECHO],[
1998 AC_MSG_CHECKING(if you want to see long compiling messages)
1999 CF_ARG_DISABLE(echo,
2000         [  --disable-echo          do not display "compiling" commands],
2001         [
2002         ECHO_LT='--silent'
2003         ECHO_LD='@echo linking [$]@;'
2004         RULE_CC='@echo compiling [$]<'
2005         SHOW_CC='@echo compiling [$]@'
2006         ECHO_CC='@'
2007 ],[
2008         ECHO_LT=''
2009         ECHO_LD=''
2010         RULE_CC=''
2011         SHOW_CC=''
2012         ECHO_CC=''
2013 ])
2014 AC_MSG_RESULT($enableval)
2015 AC_SUBST(ECHO_LT)
2016 AC_SUBST(ECHO_LD)
2017 AC_SUBST(RULE_CC)
2018 AC_SUBST(SHOW_CC)
2019 AC_SUBST(ECHO_CC)
2020 ])dnl
2021 dnl ---------------------------------------------------------------------------
2022 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
2023 dnl ------------------------
2024 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
2025 AC_MSG_CHECKING(if we want to use GNAT projects)
2026 CF_ARG_DISABLE(gnat-projects,
2027         [  --disable-gnat-projects test: disable GNAT projects even if usable],
2028         [enable_gnat_projects=no],
2029         [enable_gnat_projects=yes])
2030 AC_MSG_RESULT($enable_gnat_projects)
2031 ])dnl
2032 dnl ---------------------------------------------------------------------------
2033 dnl CF_DISABLE_LEAKS version: 9 updated: 2021/04/03 16:41:50
2034 dnl ----------------
2035 dnl Combine no-leak checks with the libraries or tools that are used for the
2036 dnl checks.
2037 AC_DEFUN([CF_DISABLE_LEAKS],[
2038
2039 AC_REQUIRE([CF_WITH_DMALLOC])
2040 AC_REQUIRE([CF_WITH_DBMALLOC])
2041 AC_REQUIRE([CF_WITH_VALGRIND])
2042
2043 AC_MSG_CHECKING(if you want to perform memory-leak testing)
2044 AC_ARG_ENABLE(leaks,
2045         [  --disable-leaks         test: free permanent memory, analyze leaks],
2046         [enable_leaks=$enableval],
2047         [enable_leaks=yes])
2048 dnl with_no_leaks is more readable...
2049 if test "x$enable_leaks" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi
2050 AC_MSG_RESULT($with_no_leaks)
2051
2052 if test "$enable_leaks" = no ; then
2053         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
2054         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
2055 fi
2056 ])dnl
2057 dnl ---------------------------------------------------------------------------
2058 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
2059 dnl --------------------------
2060 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
2061 dnl the older "-version-info" feature.  The newer feature allows us to use
2062 dnl version numbering on shared libraries which make them compatible with
2063 dnl various systems.
2064 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
2065 [
2066 AC_MSG_CHECKING(if libtool -version-number should be used)
2067 CF_ARG_DISABLE(libtool-version,
2068         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
2069         [cf_libtool_version=no],
2070         [cf_libtool_version=yes])
2071 AC_MSG_RESULT($cf_libtool_version)
2072
2073 if test "$cf_libtool_version" = yes ; then
2074         LIBTOOL_VERSION="-version-number"
2075 else
2076         LIBTOOL_VERSION="-version-info"
2077         case "x$VERSION" in
2078         (x)
2079                 AC_MSG_WARN(VERSION was not set)
2080                 ;;
2081         (x*.*.*)
2082                 ABI_VERSION="$VERSION"
2083                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
2084                 ;;
2085         (x*:*:*)
2086                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
2087                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
2088                 ;;
2089         (*)
2090                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
2091                 ;;
2092         esac
2093 fi
2094
2095 AC_SUBST(ABI_VERSION)
2096 AC_SUBST(LIBTOOL_VERSION)
2097 ])dnl
2098 dnl ---------------------------------------------------------------------------
2099 dnl CF_DISABLE_RPATH_HACK version: 3 updated: 2021/01/05 20:14:44
2100 dnl ---------------------
2101 dnl The rpath-hack makes it simpler to build programs, particularly with the
2102 dnl *BSD ports which may have essential libraries in unusual places.  But it
2103 dnl can interfere with building an executable for the base system.  Use this
2104 dnl option in that case.
2105 AC_DEFUN([CF_DISABLE_RPATH_HACK],
2106 [
2107 AC_MSG_CHECKING(if rpath-hack should be disabled)
2108 CF_ARG_DISABLE(rpath-hack,
2109         [  --disable-rpath-hack    don't add rpath options for additional libraries],
2110         [enable_rpath_hack=no],
2111         [enable_rpath_hack=yes])
2112 dnl TODO - drop cf_disable_rpath_hack
2113 if test "x$enable_rpath_hack" = xno; then cf_disable_rpath_hack=yes; else cf_disable_rpath_hack=no; fi
2114 AC_MSG_RESULT($cf_disable_rpath_hack)
2115
2116 if test "$enable_rpath_hack" = yes ; then
2117         CF_RPATH_HACK
2118 fi
2119 ])
2120 dnl ---------------------------------------------------------------------------
2121 dnl CF_ENABLE_BROKEN_LINKER version: 2 updated: 2021/01/02 17:09:14
2122 dnl -----------------------
2123 dnl Some linkers cannot reference a data-only object.  Cygwin used to be one.
2124 dnl This usually follows CF_LINK_DATAONLY, but is not required in case we need
2125 dnl an unconditional feature.
2126 AC_DEFUN([CF_ENABLE_BROKEN_LINKER],[
2127
2128 AC_MSG_CHECKING(if you want broken-linker support code)
2129 AC_ARG_ENABLE(broken_linker,
2130         [  --enable-broken_linker  compile with broken-linker support code],
2131         [with_broken_linker=$enableval],
2132         [with_broken_linker=no])
2133 AC_MSG_RESULT($with_broken_linker)
2134
2135 : "${BROKEN_LINKER:=0}"
2136 if test "x$with_broken_linker" = xyes ; then
2137         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
2138         BROKEN_LINKER=1
2139 fi
2140 AC_SUBST(BROKEN_LINKER)
2141 ])dnl
2142 dnl ---------------------------------------------------------------------------
2143 dnl CF_ENABLE_PC_FILES version: 16 updated: 2021/11/20 12:48:37
2144 dnl ------------------
2145 dnl This is the "--enable-pc-files" option, which is available if there is a
2146 dnl pkg-config configuration on the local machine.
2147 AC_DEFUN([CF_ENABLE_PC_FILES],[
2148 AC_REQUIRE([CF_PKG_CONFIG])
2149 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
2150
2151 if test "x$PKG_CONFIG" != xnone
2152 then
2153         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
2154 else
2155         AC_MSG_CHECKING(if we should install .pc files)
2156 fi
2157
2158 AC_ARG_ENABLE(pc-files,
2159         [  --enable-pc-files       generate and install .pc files for pkg-config],
2160         [enable_pc_files=$enableval],
2161         [enable_pc_files=no])
2162 AC_MSG_RESULT($enable_pc_files)
2163
2164 if test "x$enable_pc_files" != xno
2165 then
2166         MAKE_PC_FILES=
2167         case "x$PKG_CONFIG_LIBDIR" in
2168         (xno|xnone|xyes|x)
2169                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
2170                 ;;
2171         (*)
2172                 cf_pkg_config_libdir="$PKG_CONFIG_LIBDIR"
2173                 CF_PATH_SYNTAX(cf_pkg_config_libdir)
2174                 ;;
2175         esac
2176 else
2177         MAKE_PC_FILES="#"
2178 fi
2179 AC_SUBST(MAKE_PC_FILES)
2180 ])dnl
2181 dnl ---------------------------------------------------------------------------
2182 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
2183 dnl ---------------
2184 dnl Check if the rpath option should be used, setting cache variable
2185 dnl cf_cv_enable_rpath if so.
2186 AC_DEFUN([CF_ENABLE_RPATH],
2187 [
2188 AC_MSG_CHECKING(if rpath option should be used)
2189 AC_ARG_ENABLE(rpath,
2190 [  --enable-rpath          use rpath option when generating shared libraries],
2191 [cf_cv_enable_rpath=$enableval],
2192 [cf_cv_enable_rpath=no])
2193 AC_MSG_RESULT($cf_cv_enable_rpath)
2194 ])dnl
2195 dnl ---------------------------------------------------------------------------
2196 dnl CF_ENABLE_STRING_HACKS version: 6 updated: 2021/01/05 19:23:48
2197 dnl ----------------------
2198 dnl On a few platforms, the compiler and/or loader nags with untruthful
2199 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
2200 dnl and implying that most uses of the recommended alternatives are correct.
2201 dnl
2202 dnl Factually speaking, no one has actually counted the number of uses of these
2203 dnl functions versus the total of incorrect uses.  Samples of a few thousand
2204 dnl instances are meaningless compared to the hundreds of millions of lines of
2205 dnl existing C code.
2206 dnl
2207 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
2208 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
2209 dnl standard - but evolved through phases, and older implementations are likely
2210 dnl to yield surprising results, as documented in manpages on various systems.
2211 AC_DEFUN([CF_ENABLE_STRING_HACKS],
2212 [
2213 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
2214 AC_ARG_ENABLE(string-hacks,
2215         [  --enable-string-hacks   work around bogus compiler/loader warnings],
2216         [enable_string_hacks=$enableval],
2217         [enable_string_hacks=no])
2218 AC_MSG_RESULT($enable_string_hacks)
2219
2220 if test "x$enable_string_hacks" = "xyes"; then
2221         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
2222         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
2223         AC_CHECK_FUNC(strlcat,[
2224                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2225                 ],[
2226                 AC_CHECK_LIB(bsd,strlcat,[
2227                         CF_ADD_LIB(bsd)
2228                         AC_CHECK_HEADERS(bsd/string.h)
2229                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2230                         ])
2231                 ])
2232         AC_CHECK_FUNCS( strlcpy snprintf )
2233 fi
2234 ])dnl
2235 dnl ---------------------------------------------------------------------------
2236 dnl CF_ENABLE_WARNINGS version: 9 updated: 2021/01/05 19:40:50
2237 dnl ------------------
2238 dnl Configure-option to enable gcc warnings
2239 dnl
2240 dnl $1 = extra options to add, if supported
2241 dnl $2 = option for checking attributes.  By default, this is done when
2242 dnl      warnings are enabled.  For other values:
2243 dnl      yes: always do this, e.g., to use in generated library-headers
2244 dnl      no: never do this
2245 AC_DEFUN([CF_ENABLE_WARNINGS],[
2246 if test "$GCC" = yes || test "$GXX" = yes
2247 then
2248 CF_FIX_WARNINGS(CFLAGS)
2249 CF_FIX_WARNINGS(CPPFLAGS)
2250 CF_FIX_WARNINGS(LDFLAGS)
2251 AC_MSG_CHECKING(if you want to turn on gcc warnings)
2252 CF_ARG_ENABLE(warnings,
2253         [  --enable-warnings       test: turn on gcc compiler warnings],
2254         [enable_warnings=yes],
2255         [enable_warnings=no])
2256 AC_MSG_RESULT($enable_warnings)
2257 if test "$enable_warnings" = "yes"
2258 then
2259         ifelse($2,,[CF_GCC_ATTRIBUTES])
2260         CF_GCC_WARNINGS($1)
2261 fi
2262 ifelse($2,yes,[CF_GCC_ATTRIBUTES])
2263 fi
2264 ])dnl
2265 dnl ---------------------------------------------------------------------------
2266 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
2267 dnl --------
2268 dnl Check if 'errno' is declared in <errno.h>
2269 AC_DEFUN([CF_ERRNO],
2270 [
2271 CF_CHECK_ERRNO(errno)
2272 ])dnl
2273 dnl ---------------------------------------------------------------------------
2274 dnl CF_ETIP_DEFINES version: 6 updated: 2021/01/02 17:09:14
2275 dnl ---------------
2276 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
2277 dnl math.h and builtin.h, only for ncurses
2278 AC_DEFUN([CF_ETIP_DEFINES],
2279 [
2280 AC_MSG_CHECKING(for special defines needed for etip.h)
2281 cf_save_CXXFLAGS="$CXXFLAGS"
2282 cf_result="none"
2283
2284 # etip.h includes ncurses.h which includes ncurses_dll.h
2285 # But ncurses_dll.h is generated - fix here.
2286 test -d include || mkdir include
2287 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' "${srcdir}/include/ncurses_dll.h.in" >include/ncurses_dll.h
2288
2289 for cf_math in "" MATH_H
2290 do
2291 for cf_excp in "" MATH_EXCEPTION
2292 do
2293         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
2294         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
2295         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
2296 AC_TRY_COMPILE([
2297 #include <etip.h.in>
2298 ],[],[
2299         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
2300         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
2301         cf_result="$cf_math $cf_excp"
2302         break 2
2303 ],[])
2304 done
2305 done
2306 AC_MSG_RESULT($cf_result)
2307 CXXFLAGS="$cf_save_CXXFLAGS"
2308 ])
2309 dnl ---------------------------------------------------------------------------
2310 dnl CF_FIND_LINKAGE version: 22 updated: 2020/12/31 20:19:42
2311 dnl ---------------
2312 dnl Find a library (specifically the linkage used in the code fragment),
2313 dnl searching for it if it is not already in the library path.
2314 dnl See also CF_ADD_SEARCHPATH.
2315 dnl
2316 dnl Parameters (4-on are optional):
2317 dnl     $1 = headers for library entrypoint
2318 dnl     $2 = code fragment for library entrypoint
2319 dnl     $3 = the library name without the "-l" option or ".so" suffix.
2320 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
2321 dnl     $5 = action to perform if not successful
2322 dnl     $6 = module name, if not the same as the library name
2323 dnl     $7 = extra libraries
2324 dnl
2325 dnl Sets these variables:
2326 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
2327 dnl     $cf_cv_header_path_$3 - include-directory if needed
2328 dnl     $cf_cv_library_path_$3 - library-directory if needed
2329 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
2330 AC_DEFUN([CF_FIND_LINKAGE],[
2331
2332 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
2333 # will be set on completion of the AC_TRY_LINK below.
2334 cf_cv_header_path_$3=
2335 cf_cv_library_path_$3=
2336
2337 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
2338
2339 cf_save_LIBS="$LIBS"
2340
2341 AC_TRY_LINK([$1],[$2],[
2342         cf_cv_find_linkage_$3=yes
2343         cf_cv_header_path_$3=/usr/include
2344         cf_cv_library_path_$3=/usr/lib
2345 ],[
2346
2347 LIBS="-l$3 $7 $cf_save_LIBS"
2348
2349 AC_TRY_LINK([$1],[$2],[
2350         cf_cv_find_linkage_$3=yes
2351         cf_cv_header_path_$3=/usr/include
2352         cf_cv_library_path_$3=/usr/lib
2353         cf_cv_library_file_$3="-l$3"
2354 ],[
2355         cf_cv_find_linkage_$3=no
2356         LIBS="$cf_save_LIBS"
2357
2358         CF_VERBOSE(find linkage for $3 library)
2359         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
2360
2361         cf_save_CPPFLAGS="$CPPFLAGS"
2362         cf_test_CPPFLAGS="$CPPFLAGS"
2363
2364         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
2365         for cf_cv_header_path_$3 in $cf_search
2366         do
2367                 if test -d "$cf_cv_header_path_$3" ; then
2368                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
2369                         CPPFLAGS="$cf_save_CPPFLAGS"
2370                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
2371                         AC_TRY_COMPILE([$1],[$2],[
2372                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
2373                                 cf_cv_find_linkage_$3=maybe
2374                                 cf_test_CPPFLAGS="$CPPFLAGS"
2375                                 break],[
2376                                 CPPFLAGS="$cf_save_CPPFLAGS"
2377                                 ])
2378                 fi
2379         done
2380
2381         if test "$cf_cv_find_linkage_$3" = maybe ; then
2382
2383                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
2384
2385                 cf_save_LIBS="$LIBS"
2386                 cf_save_LDFLAGS="$LDFLAGS"
2387
2388                 ifelse([$6],,,[
2389                 CPPFLAGS="$cf_test_CPPFLAGS"
2390                 LIBS="-l$3 $7 $cf_save_LIBS"
2391                 AC_TRY_LINK([$1],[$2],[
2392                         CF_VERBOSE(... found $3 library in system)
2393                         cf_cv_find_linkage_$3=yes])
2394                         CPPFLAGS="$cf_save_CPPFLAGS"
2395                         LIBS="$cf_save_LIBS"
2396                         ])
2397
2398                 if test "$cf_cv_find_linkage_$3" != yes ; then
2399                         CF_LIBRARY_PATH(cf_search,$3)
2400                         for cf_cv_library_path_$3 in $cf_search
2401                         do
2402                                 if test -d "$cf_cv_library_path_$3" ; then
2403                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
2404                                         CPPFLAGS="$cf_test_CPPFLAGS"
2405                                         LIBS="-l$3 $7 $cf_save_LIBS"
2406                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
2407                                         AC_TRY_LINK([$1],[$2],[
2408                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
2409                                         cf_cv_find_linkage_$3=yes
2410                                         cf_cv_library_file_$3="-l$3"
2411                                         break],[
2412                                         CPPFLAGS="$cf_save_CPPFLAGS"
2413                                         LIBS="$cf_save_LIBS"
2414                                         LDFLAGS="$cf_save_LDFLAGS"
2415                                         ])
2416                                 fi
2417                         done
2418                         CPPFLAGS="$cf_save_CPPFLAGS"
2419                         LDFLAGS="$cf_save_LDFLAGS"
2420                 fi
2421
2422         else
2423                 cf_cv_find_linkage_$3=no
2424         fi
2425         ],$7)
2426 ])
2427
2428 LIBS="$cf_save_LIBS"
2429
2430 if test "$cf_cv_find_linkage_$3" = yes ; then
2431 ifelse([$4],,[
2432         CF_ADD_INCDIR($cf_cv_header_path_$3)
2433         CF_ADD_LIBDIR($cf_cv_library_path_$3)
2434         CF_ADD_LIB($3)
2435 ],[$4])
2436 else
2437 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
2438 fi
2439 ])dnl
2440 dnl ---------------------------------------------------------------------------
2441 dnl CF_FIND_SUB_INCDIR version: 3 updated: 2021/01/01 13:31:04
2442 dnl ------------------
2443 dnl Find an include-directory with the given leaf-name.  This is useful for
2444 dnl example with FreeBSD ports, which use this convention to distinguish
2445 dnl different versions of the same port.
2446 AC_DEFUN([CF_FIND_SUB_INCDIR],[
2447         CF_SUBDIR_PATH(cf_search,$1,include)
2448         for cf_item in $cf_search
2449         do
2450                 case "$cf_item" in
2451                 (*/$1)
2452                         CF_ADD_INCDIR($cf_item)
2453                         ;;
2454                 esac
2455         done
2456 ])dnl
2457 dnl ---------------------------------------------------------------------------
2458 dnl CF_FIND_SUB_LIBDIR version: 3 updated: 2021/01/01 13:31:04
2459 dnl ------------------
2460 dnl Find a library-directory with the given leaf-name.  This is useful for
2461 dnl example with FreeBSD ports, which use this convention to distinguish
2462 dnl different versions of the same port.
2463 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
2464         CF_SUBDIR_PATH(cf_search,$1,lib)
2465         for cf_item in $cf_search
2466         do
2467                 case "$cf_item" in
2468                 (*/$1)
2469                         CF_ADD_LIBDIR($cf_item)
2470                         ;;
2471                 esac
2472         done
2473 ])dnl
2474 dnl ---------------------------------------------------------------------------
2475 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
2476 dnl -----------------
2477 dnl make ADAFLAGS consistent with CFLAGS
2478 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
2479         AC_MSG_CHECKING(optimization options for ADAFLAGS)
2480         case "$CFLAGS" in
2481         (*-g*)
2482                 CF_ADD_ADAFLAGS(-g)
2483                 ;;
2484         esac
2485         case "$CFLAGS" in
2486         (*-O*)
2487                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
2488                 CF_ADD_ADAFLAGS($cf_O_flag)
2489                 ;;
2490         esac
2491         AC_MSG_RESULT($ADAFLAGS)
2492 ])dnl
2493 dnl ---------------------------------------------------------------------------
2494 dnl CF_FIX_WARNINGS version: 4 updated: 2021/12/16 18:22:31
2495 dnl ---------------
2496 dnl Warning flags do not belong in CFLAGS, CPPFLAGS, etc.  Any of gcc's
2497 dnl "-Werror" flags can interfere with configure-checks.  Those go into
2498 dnl EXTRA_CFLAGS.
2499 dnl
2500 dnl $1 = variable name to repair
2501 define([CF_FIX_WARNINGS],[
2502 if test "$GCC" = yes || test "$GXX" = yes
2503 then
2504         case [$]$1 in
2505         (*-Werror=*)
2506                 cf_temp_flags=
2507                 for cf_temp_scan in [$]$1
2508                 do
2509                         case "x$cf_temp_scan" in
2510                         (x-Werror=format*)
2511                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
2512                                 ;;
2513                         (x-Werror=*)
2514                                 CF_APPEND_TEXT(EXTRA_CFLAGS,$cf_temp_scan)
2515                                 ;;
2516                         (*)
2517                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
2518                                 ;;
2519                         esac
2520                 done
2521                 if test "x[$]$1" != "x$cf_temp_flags"
2522                 then
2523                         CF_VERBOSE(repairing $1: [$]$1)
2524                         $1="$cf_temp_flags"
2525                         CF_VERBOSE(... fixed [$]$1)
2526                         CF_VERBOSE(... extra $EXTRA_CFLAGS)
2527                 fi
2528                 ;;
2529         esac
2530 fi
2531 AC_SUBST(EXTRA_CFLAGS)
2532 ])dnl
2533 dnl ---------------------------------------------------------------------------
2534 dnl CF_FOPEN_BIN_R version: 3 updated: 2023/01/05 18:05:46
2535 dnl --------------
2536 dnl Check if fopen works when the "b" (binary) flag is added to the mode
2537 dnl parameter.  POSIX ignores the "b", which c89 specified.  Some very old
2538 dnl systems do not accept it.
2539 AC_DEFUN([CF_FOPEN_BIN_R],[
2540 AC_CACHE_CHECK(if fopen accepts explicit binary mode,cf_cv_fopen_bin_r,[
2541         AC_TRY_RUN([
2542 $ac_includes_default
2543
2544 int main(void)
2545 {
2546         FILE *fp = fopen("conftest.tmp", "wb");
2547         int rc = 0;
2548         if (fp != 0) {
2549                 int p, q;
2550                 for (p = 0; p < 256; ++p) {
2551                         fputc(p, fp);
2552                 }
2553                 fclose(fp);
2554                 fp = fopen("conftest.tmp", "rb");
2555                 if (fp != 0) {
2556                         for (p = 0; p < 256; ++p) {
2557                                 q = fgetc(fp);
2558                                 if (q != p) {
2559                                         rc = 1;
2560                                         break;
2561                                 }
2562                         }
2563                 } else {
2564                         rc = 1;
2565                 }
2566         } else {
2567                 rc = 1;
2568         }
2569         ${cf_cv_main_return:-return} (rc);
2570 }
2571 ],
2572                 [cf_cv_fopen_bin_r=yes],
2573                 [cf_cv_fopen_bin_r=no],
2574                 [cf_cv_fopen_bin_r=unknown])
2575 ])
2576 test "x$cf_cv_fopen_bin_r" != xno && AC_DEFINE(USE_FOPEN_BIN_R,1,[Define to 1 if fopen accepts explicit binary mode])
2577 ])dnl
2578 dnl ---------------------------------------------------------------------------
2579 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
2580 dnl --------------
2581 dnl Forget that we saw the given tool.
2582 AC_DEFUN([CF_FORGET_TOOL],[
2583 unset ac_cv_prog_ac_ct_$1
2584 unset ac_ct_$1
2585 unset $1
2586 ])dnl
2587 dnl ---------------------------------------------------------------------------
2588 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
2589 dnl -------------
2590 dnl Test for dlsym() and related functions, as well as libdl.
2591 dnl
2592 dnl Sets
2593 dnl     $cf_have_dlsym
2594 dnl     $cf_have_libdl
2595 AC_DEFUN([CF_FUNC_DLSYM],[
2596 cf_have_dlsym=no
2597 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
2598
2599 cf_have_libdl=no
2600 AC_CHECK_LIB(dl,dlsym,[
2601         cf_have_dlsym=yes
2602         cf_have_libdl=yes])])
2603
2604 if test "$cf_have_dlsym" = yes ; then
2605         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
2606
2607         AC_MSG_CHECKING(whether able to link to dl*() functions)
2608         AC_TRY_LINK([#include <dlfcn.h>],[
2609                 void *obj;
2610                 if ((obj = dlopen("filename", 0)) != 0) {
2611                         if (dlsym(obj, "symbolname") == 0) {
2612                         dlclose(obj);
2613                         }
2614                 }],[
2615                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
2616                 AC_MSG_ERROR(Cannot link test program for libdl)])
2617         AC_MSG_RESULT(ok)
2618 else
2619         AC_MSG_ERROR(Cannot find dlsym function)
2620 fi
2621 ])
2622 dnl ---------------------------------------------------------------------------
2623 dnl CF_FUNC_GETTIME version: 2 updated: 2023/02/25 08:45:56
2624 dnl ---------------
2625 dnl Check for gettimeofday or clock_gettime.  In 2023, the former is still more
2626 dnl widely supported, but "deprecated" (2008), so we will use the latter if it
2627 dnl is available, to reduce compiler warnings.
2628 AC_DEFUN([CF_FUNC_GETTIME],[
2629 AC_CACHE_CHECK(for clock_gettime,cf_cv_func_clock_gettime,[
2630                 AC_TRY_LINK([#include <time.h>],
2631                 [struct timespec ts;
2632                 int rc = clock_gettime(CLOCK_REALTIME, &ts); (void) rc; (void)ts],
2633                 [cf_cv_func_clock_gettime=yes],
2634                 [cf_cv_func_clock_gettime=no])
2635 ])
2636
2637 if test "$cf_cv_func_clock_gettime" = yes
2638 then
2639         AC_DEFINE(HAVE_CLOCK_GETTIME,1,[Define to 1 if we have clock_gettime function])
2640 else
2641 AC_CHECK_FUNC(gettimeofday,
2642         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
2643
2644 AC_CHECK_LIB(bsd, gettimeofday,
2645         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
2646         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
2647 fi
2648 ])dnl
2649 dnl ---------------------------------------------------------------------------
2650 dnl CF_FUNC_GETTTYNAM version: 2 updated: 2023/01/05 18:06:28
2651 dnl -----------------
2652 dnl Check if the 4.3BSD function getttyname exists, as well as if <ttyent.h>
2653 dnl defines the _PATH_TTYS symbol.  If the corresponding file exists, but the
2654 dnl other checks fail, just define HAVE_PATH_TTYS.
2655 AC_DEFUN([CF_FUNC_GETTTYNAM],[
2656 AC_CACHE_CHECK(if _PATH_TTYS is defined in ttyent.h,cf_cv_PATH_TTYS,[
2657 AC_TRY_COMPILE([
2658 #include <stdio.h>
2659 #include <ttyent.h>],[
2660 FILE *fp = fopen(_PATH_TTYS, "r"); (void)fp],
2661         [cf_cv_PATH_TTYS=yes],
2662         [cf_cv_PATH_TTYS=no])])
2663
2664 if test $cf_cv_PATH_TTYS = no
2665 then
2666         for cf_ttys in /etc/ttytype /etc/ttys
2667         do
2668                 if test -f $cf_ttys
2669                 then
2670                         cf_cv_PATH_TTYS=maybe
2671                         AC_DEFINE(_PATH_TTYS,$cf_ttys,[define to pathname of file containing mapping from tty name to terminal type])
2672                         break
2673                 fi
2674         done
2675 fi
2676
2677 if test $cf_cv_PATH_TTYS != no
2678 then
2679         AC_CACHE_CHECK(if _PATH_TTYS file exists,cf_cv_have_PATH_TTYS,[
2680                 AC_TRY_RUN([
2681 $ac_includes_default
2682
2683 #include <ttyent.h>
2684
2685 int main(void) {
2686         FILE *fp = fopen(_PATH_TTYS, "r");
2687         ${cf_cv_main_return:-return} (fp == 0);
2688 }],
2689                         [cf_cv_have_PATH_TTYS=yes],
2690                         [cf_cv_have_PATH_TTYS=no],
2691                         [cf_cv_have_PATH_TTYS=unknown])])
2692         test "$cf_cv_have_PATH_TTYS" = no && cf_cv_PATH_TTYS=no
2693 fi
2694
2695 if test $cf_cv_PATH_TTYS != no
2696 then
2697         AC_DEFINE(HAVE_PATH_TTYS,1,[define to 1 if system can map tty name to terminal type])
2698         AC_CACHE_CHECK(for getttynam,cf_cv_func_getttynam,[
2699                 AC_TRY_LINK([#include <ttyent.h>],
2700                 [struct ttyent *fp = getttynam("/dev/tty"); (void)fp],
2701                 [cf_cv_func_getttynam=yes],
2702                 [cf_cv_func_getttynam=no])])
2703         test "$cf_cv_func_getttynam" = yes && AC_DEFINE(HAVE_GETTTYNAM)
2704 fi
2705 ])dnl
2706 dnl ---------------------------------------------------------------------------
2707 dnl CF_FUNC_MEMMOVE version: 10 updated: 2023/01/05 18:51:28
2708 dnl ---------------
2709 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
2710 dnl is found, add our own version of memmove to the list of objects.
2711 AC_DEFUN([CF_FUNC_MEMMOVE],
2712 [
2713 AC_CHECK_FUNC(memmove,,[
2714 AC_CHECK_FUNC(bcopy,[
2715         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
2716                 AC_TRY_RUN([
2717 $ac_includes_default
2718
2719 int main(void) {
2720         static char data[] = "abcdefghijklmnopqrstuwwxyz";
2721         char temp[40];
2722         bcopy(data, temp, sizeof(data));
2723         bcopy(temp+10, temp, 15);
2724         bcopy(temp+5, temp+15, 10);
2725         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
2726 }
2727                 ],
2728                 [cf_cv_good_bcopy=yes],
2729                 [cf_cv_good_bcopy=no],
2730                 [cf_cv_good_bcopy=unknown])
2731                 ])
2732         ],[cf_cv_good_bcopy=no])
2733         if test "$cf_cv_good_bcopy" = yes ; then
2734                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
2735         else
2736                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
2737         fi
2738 ])])dnl
2739 dnl ---------------------------------------------------------------------------
2740 dnl CF_FUNC_NANOSLEEP version: 6 updated: 2023/01/05 18:51:33
2741 dnl -----------------
2742 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
2743 dnl AIX 4.x, provide a non-working version.
2744 AC_DEFUN([CF_FUNC_NANOSLEEP],[
2745 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
2746 AC_TRY_RUN([
2747 $ac_includes_default
2748
2749 #include <errno.h>
2750 #include <time.h>
2751
2752 #ifdef HAVE_SYS_TIME_H
2753 #include <sys/time.h>
2754 #endif
2755
2756 int main(void) {
2757         struct timespec ts1, ts2;
2758         int code;
2759         ts1.tv_sec  = 0;
2760         ts1.tv_nsec = 750000000;
2761         ts2.tv_sec  = 0;
2762         ts2.tv_nsec = 0;
2763         errno = 0;
2764         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
2765         ${cf_cv_main_return:-return}(code != 0);
2766 }
2767 ],
2768         [cf_cv_func_nanosleep=yes],
2769         [cf_cv_func_nanosleep=no],
2770         [cf_cv_func_nanosleep=unknown])])
2771
2772 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
2773 ])
2774 dnl ---------------------------------------------------------------------------
2775 dnl CF_FUNC_OPENPTY version: 6 updated: 2021/01/01 13:31:04
2776 dnl ---------------
2777 dnl Check for openpty() function, along with <pty.h> header.  It may need the
2778 dnl "util" library as well.
2779 AC_DEFUN([CF_FUNC_OPENPTY],
2780 [
2781 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
2782 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
2783         cf_save_LIBS="$LIBS"
2784         test "$cf_cv_lib_util" = yes && { CF_ADD_LIB(util) }
2785         for cf_header in pty.h libutil.h util.h
2786         do
2787         AC_TRY_LINK([
2788 #include <$cf_header>
2789 ],[
2790         int x = openpty((int *)0, (int *)0, (char *)0,
2791                                    (struct termios *)0, (struct winsize *)0);
2792 ],[
2793                 cf_cv_func_openpty=$cf_header
2794                 break
2795 ],[
2796                 cf_cv_func_openpty=no
2797 ])
2798         done
2799         LIBS="$cf_save_LIBS"
2800 ])
2801 ])dnl
2802 dnl ---------------------------------------------------------------------------
2803 dnl CF_FUNC_POLL version: 11 updated: 2023/01/05 18:51:40
2804 dnl ------------
2805 dnl See if the poll function really works.  Some platforms have poll(), but
2806 dnl it does not work for terminals or files.
2807 AC_DEFUN([CF_FUNC_POLL],[
2808 tty >/dev/null 2>&1 || { AC_CHECK_FUNCS(posix_openpt) }
2809 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2810 AC_TRY_RUN([
2811 $ac_includes_default
2812
2813 #include <fcntl.h>
2814
2815 #ifdef HAVE_POLL_H
2816 #include <poll.h>
2817 #else
2818 #include <sys/poll.h>
2819 #endif
2820
2821 int main(void) {
2822         struct pollfd myfds;
2823         int ret;
2824
2825         /* check for Darwin bug with respect to "devices" */
2826         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2827         if (myfds.fd < 0)
2828                 myfds.fd = 0;
2829         myfds.events = POLLIN;
2830         myfds.revents = 0;
2831
2832         ret = poll(&myfds, 1, 100);
2833
2834         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2835                 ret = -1;
2836         } else {
2837                 int fd = 0;
2838                 if (!isatty(fd)) {
2839                         fd = open("/dev/tty", 2);       /* O_RDWR */
2840                 }
2841 #ifdef HAVE_POSIX_OPENPT
2842                 if (fd < 0) {
2843                         fd = posix_openpt(O_RDWR);
2844                 }
2845 #endif
2846
2847                 if (fd >= 0) {
2848                         /* also check with standard input */
2849                         myfds.fd = fd;
2850                         myfds.events = POLLIN;
2851                         myfds.revents = 0;
2852                         ret = poll(&myfds, 1, 100);
2853                 } else {
2854                         ret = -1;
2855                 }
2856         }
2857         ${cf_cv_main_return:-return}(ret < 0);
2858 }],
2859         [cf_cv_working_poll=yes],
2860         [cf_cv_working_poll=no],
2861         [cf_cv_working_poll=unknown])])
2862 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2863 ])dnl
2864 dnl ---------------------------------------------------------------------------
2865 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2866 dnl ---------------
2867 dnl Some old/broken variations define tcgetattr() only as a macro in
2868 dnl termio(s).h
2869 AC_DEFUN([CF_FUNC_TERMIOS],[
2870 AC_REQUIRE([CF_STRUCT_TERMIOS])
2871 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2872 AC_TRY_LINK([
2873 #include <sys/types.h>
2874 #ifdef HAVE_UNISTD_H
2875 #include <unistd.h>
2876 #endif
2877 #ifdef HAVE_TERMIOS_H
2878 #include <termios.h>
2879 #define TTY struct termios
2880 #else
2881 #ifdef HAVE_TERMIO_H
2882 #include <termio.h>
2883 #define TTY struct termio
2884 #endif
2885 #endif
2886 ],[
2887 TTY foo;
2888 tcgetattr(1, &foo);],
2889 [cf_cv_have_tcgetattr=yes],
2890 [cf_cv_have_tcgetattr=no])])
2891 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2892 ])dnl
2893 dnl ---------------------------------------------------------------------------
2894 dnl CF_FUNC_VSSCANF version: 7 updated: 2021/01/01 13:31:04
2895 dnl ---------------
2896 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2897 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2898 dnl other functions.
2899 AC_DEFUN([CF_FUNC_VSSCANF],
2900 [
2901 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2902 AC_TRY_LINK([
2903 #include <stdarg.h>
2904 #include <stdio.h>],[
2905         va_list ap;
2906         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2907 AC_TRY_LINK([
2908 #include <stdarg.h>
2909 #include <stdio.h>],[
2910         FILE strbuf;
2911         char *str = "from";
2912
2913         strbuf._flag = _IOREAD;
2914         strbuf._ptr = strbuf._base = (unsigned char *) str;
2915         strbuf._cnt = strlen(str);
2916         strbuf._file = _NFILE;
2917         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2918 AC_TRY_LINK([
2919 #include <stdarg.h>
2920 #include <stdio.h>],[
2921         FILE strbuf;
2922         char *str = "from";
2923
2924         strbuf._flag = _IOREAD;
2925         strbuf._ptr = strbuf._base = (unsigned char *) str;
2926         strbuf._cnt = strlen(str);
2927         strbuf._file = _NFILE;
2928         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2929 cf_cv_func_vsscanf=no])])])])
2930
2931 case "$cf_cv_func_vsscanf" in
2932 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2933 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2934 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2935 esac
2936
2937 ])dnl
2938 dnl ---------------------------------------------------------------------------
2939 dnl CF_GCC_ATTRIBUTES version: 24 updated: 2021/03/20 12:00:25
2940 dnl -----------------
2941 dnl Test for availability of useful gcc __attribute__ directives to quiet
2942 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2943 dnl to documentation, unrecognized directives cause older compilers to barf.
2944 AC_DEFUN([CF_GCC_ATTRIBUTES],
2945 [AC_REQUIRE([AC_PROG_FGREP])dnl
2946 AC_REQUIRE([CF_C11_NORETURN])dnl
2947
2948 if test "$GCC" = yes || test "$GXX" = yes
2949 then
2950 cat > conftest.i <<EOF
2951 #ifndef GCC_PRINTF
2952 #define GCC_PRINTF 0
2953 #endif
2954 #ifndef GCC_SCANF
2955 #define GCC_SCANF 0
2956 #endif
2957 #ifndef GCC_NORETURN
2958 #define GCC_NORETURN /* nothing */
2959 #endif
2960 #ifndef GCC_UNUSED
2961 #define GCC_UNUSED /* nothing */
2962 #endif
2963 EOF
2964 if test "$GCC" = yes
2965 then
2966         AC_CHECKING([for $CC __attribute__ directives])
2967 cat > "conftest.$ac_ext" <<EOF
2968 #line __oline__ "${as_me:-configure}"
2969 #include <stdio.h>
2970 #include "confdefs.h"
2971 #include "conftest.h"
2972 #include "conftest.i"
2973 #if     GCC_PRINTF
2974 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2975 #else
2976 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2977 #endif
2978 #if     GCC_SCANF
2979 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2980 #else
2981 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2982 #endif
2983 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2984 extern GCC_NORETURN void oops(char *,...) GCC_PRINTFLIKE(1,2);
2985 extern GCC_NORETURN void foo(void);
2986 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
2987 EOF
2988         cf_printf_attribute=no
2989         cf_scanf_attribute=no
2990         for cf_attribute in scanf printf unused noreturn
2991         do
2992                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2993                 cf_directive="__attribute__(($cf_attribute))"
2994                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2995
2996                 case "$cf_attribute" in
2997                 (printf)
2998                         cf_printf_attribute=yes
2999                         cat >conftest.h <<EOF
3000 #define GCC_$cf_ATTRIBUTE 1
3001 EOF
3002                         ;;
3003                 (scanf)
3004                         cf_scanf_attribute=yes
3005                         cat >conftest.h <<EOF
3006 #define GCC_$cf_ATTRIBUTE 1
3007 EOF
3008                         ;;
3009                 (*)
3010                         cat >conftest.h <<EOF
3011 #define GCC_$cf_ATTRIBUTE $cf_directive
3012 EOF
3013                         ;;
3014                 esac
3015
3016                 if AC_TRY_EVAL(ac_compile); then
3017                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
3018                         cat conftest.h >>confdefs.h
3019                         case "$cf_attribute" in
3020                         (noreturn)
3021                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
3022                                 ;;
3023                         (printf)
3024                                 cf_value='/* nothing */'
3025                                 if test "$cf_printf_attribute" != no ; then
3026                                         cf_value='__attribute__((format(printf,fmt,var)))'
3027                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
3028                                 fi
3029                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
3030                                 ;;
3031                         (scanf)
3032                                 cf_value='/* nothing */'
3033                                 if test "$cf_scanf_attribute" != no ; then
3034                                         cf_value='__attribute__((format(scanf,fmt,var)))'
3035                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
3036                                 fi
3037                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
3038                                 ;;
3039                         (unused)
3040                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
3041                                 ;;
3042                         esac
3043                 fi
3044         done
3045 else
3046         ${FGREP-fgrep} define conftest.i >>confdefs.h
3047 fi
3048 rm -rf ./conftest*
3049 fi
3050 ])dnl
3051 dnl ---------------------------------------------------------------------------
3052 dnl CF_GCC_VERSION version: 9 updated: 2023/03/05 14:30:13
3053 dnl --------------
3054 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
3055 dnl compatible), attempt to determine if icc/clang is actually used.
3056 AC_DEFUN([CF_GCC_VERSION],[
3057 AC_REQUIRE([AC_PROG_CC])
3058 GCC_VERSION=none
3059 if test "$GCC" = yes ; then
3060         AC_MSG_CHECKING(version of $CC)
3061         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^[[^(]]*([[^)]][[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
3062         test -z "$GCC_VERSION" && GCC_VERSION=unknown
3063         AC_MSG_RESULT($GCC_VERSION)
3064 fi
3065 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
3066 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
3067 ])dnl
3068 dnl ---------------------------------------------------------------------------
3069 dnl CF_GCC_WARNINGS version: 41 updated: 2021/01/01 16:53:59
3070 dnl ---------------
3071 dnl Check if the compiler supports useful warning options.  There's a few that
3072 dnl we don't use, simply because they're too noisy:
3073 dnl
3074 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
3075 dnl     -Winline (usually not worthwhile)
3076 dnl     -Wredundant-decls (system headers make this too noisy)
3077 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
3078 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
3079 dnl             is enabled for ncurses using "--enable-const".
3080 dnl     -pedantic
3081 dnl
3082 dnl Parameter:
3083 dnl     $1 is an optional list of gcc warning flags that a particular
3084 dnl             application might want to use, e.g., "no-unused" for
3085 dnl             -Wno-unused
3086 dnl Special:
3087 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
3088 dnl
3089 AC_DEFUN([CF_GCC_WARNINGS],
3090 [
3091 AC_REQUIRE([CF_GCC_VERSION])
3092 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
3093 cat > "conftest.$ac_ext" <<EOF
3094 #line __oline__ "${as_me:-configure}"
3095 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
3096 EOF
3097 if test "$INTEL_COMPILER" = yes
3098 then
3099 # The "-wdXXX" options suppress warnings:
3100 # remark #1419: external declaration in primary source file
3101 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3102 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
3103 # remark #193: zero used for undefined preprocessing identifier
3104 # remark #593: variable "curs_sb_left_arrow" was set but never used
3105 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
3106 # remark #869: parameter "tw" was never referenced
3107 # remark #981: operands are evaluated in unspecified order
3108 # warning #279: controlling expression is constant
3109
3110         AC_CHECKING([for $CC warning options])
3111         cf_save_CFLAGS="$CFLAGS"
3112         EXTRA_CFLAGS="$EXTRA_CFLAGS -Wall"
3113         for cf_opt in \
3114                 wd1419 \
3115                 wd1683 \
3116                 wd1684 \
3117                 wd193 \
3118                 wd593 \
3119                 wd279 \
3120                 wd810 \
3121                 wd869 \
3122                 wd981
3123         do
3124                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
3125                 if AC_TRY_EVAL(ac_compile); then
3126                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3127                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
3128                 fi
3129         done
3130         CFLAGS="$cf_save_CFLAGS"
3131 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
3132 then
3133         AC_CHECKING([for $CC warning options])
3134         cf_save_CFLAGS="$CFLAGS"
3135         cf_warn_CONST=""
3136         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
3137         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
3138         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
3139         for cf_opt in W Wall \
3140                 Wbad-function-cast \
3141                 Wcast-align \
3142                 Wcast-qual \
3143                 Wdeclaration-after-statement \
3144                 Wextra \
3145                 Winline \
3146                 Wmissing-declarations \
3147                 Wmissing-prototypes \
3148                 Wnested-externs \
3149                 Wpointer-arith \
3150                 Wshadow \
3151                 Wstrict-prototypes \
3152                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
3153         do
3154                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
3155                 if AC_TRY_EVAL(ac_compile); then
3156                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3157                         case "$cf_opt" in
3158                         (Winline)
3159                                 case "$GCC_VERSION" in
3160                                 ([[34]].*)
3161                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
3162                                         continue;;
3163                                 esac
3164                                 ;;
3165                         (Wpointer-arith)
3166                                 case "$GCC_VERSION" in
3167                                 ([[12]].*)
3168                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
3169                                         continue;;
3170                                 esac
3171                                 ;;
3172                         esac
3173                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
3174                 fi
3175         done
3176         CFLAGS="$cf_save_CFLAGS"
3177 fi
3178 rm -rf ./conftest*
3179
3180 AC_SUBST(EXTRA_CFLAGS)
3181 ])dnl
3182 dnl ---------------------------------------------------------------------------
3183 dnl CF_GETOPT_HEADER version: 8 updated: 2021/06/19 19:16:16
3184 dnl ----------------
3185 dnl Check for getopt's variables which are commonly defined in stdlib.h,
3186 dnl unistd.h or (nonstandard) in getopt.h
3187 AC_DEFUN([CF_GETOPT_HEADER],
3188 [
3189 AC_HAVE_HEADERS(unistd.h getopt.h)
3190 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
3191 cf_cv_getopt_header=none
3192 for cf_header in stdio.h stdlib.h unistd.h getopt.h
3193 do
3194 AC_TRY_COMPILE([
3195 #include <$cf_header>],
3196 [int x = optind; char *y = optarg; (void)x; (void)y],
3197 [cf_cv_getopt_header=$cf_header
3198  break])
3199 done
3200 ])
3201 if test "$cf_cv_getopt_header" != none ; then
3202         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
3203 fi
3204 if test "$cf_cv_getopt_header" = getopt.h ; then
3205         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
3206 fi
3207 ])dnl
3208 dnl ---------------------------------------------------------------------------
3209 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
3210 dnl -----------------
3211 AC_DEFUN([CF_GNATPREP_OPT_T],[
3212 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
3213 cf_cv_gnatprep_opt_t=no
3214 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
3215 ])
3216 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
3217 AC_SUBST(GNATPREP_OPTS)
3218 ])dnl
3219 dnl ---------------------------------------------------------------------------
3220 dnl CF_GNAT_GENERICS version: 7 updated: 2021/01/01 13:31:04
3221 dnl ----------------
3222 AC_DEFUN([CF_GNAT_GENERICS],
3223 [
3224 AC_REQUIRE([CF_GNAT_VERSION])
3225
3226 AC_MSG_CHECKING(if GNAT supports generics)
3227 case "$cf_cv_gnat_version" in
3228 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
3229         cf_gnat_generics=yes
3230         ;;
3231 (*)
3232         cf_gnat_generics=no
3233         ;;
3234 esac
3235 AC_MSG_RESULT($cf_gnat_generics)
3236
3237 if test "$cf_gnat_generics" = yes
3238 then
3239         cf_compile_generics=generics
3240         cf_generic_objects="\${GENOBJS}"
3241 else
3242         cf_compile_generics=
3243         cf_generic_objects=
3244 fi
3245
3246 AC_SUBST(cf_compile_generics)
3247 AC_SUBST(cf_generic_objects)
3248 ])dnl
3249 dnl ---------------------------------------------------------------------------
3250 dnl CF_GNAT_PROJECTS version: 13 updated: 2021/01/02 17:09:14
3251 dnl ----------------
3252 dnl GNAT projects are configured with ".gpr" project files.
3253 dnl GNAT libraries are a further development, using the project feature.
3254 AC_DEFUN([CF_GNAT_PROJECTS],
3255 [
3256 AC_REQUIRE([CF_GNAT_VERSION])
3257 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
3258
3259 cf_gnat_libraries=no
3260 cf_gnat_projects=no
3261
3262 if test "$enable_gnat_projects" != no ; then
3263 AC_MSG_CHECKING(if GNAT supports project files)
3264 case "$cf_cv_gnat_version" in
3265 (3.[[0-9]]*)
3266         ;;
3267 (*)
3268         case "$cf_cv_system_name" in
3269         (cygwin*|msys*)
3270                 ;;
3271         (*)
3272                 rm -rf ./conftest* ./*~conftest*
3273                 if mkdir conftest.src conftest.bin conftest.lib
3274                 then
3275                         cd conftest.src
3276                         rm -rf ./conftest* ./*~conftest*
3277                         cat >>library.gpr <<CF_EOF
3278 project Library is
3279   Kind := External ("LIB_KIND");
3280   for Library_Name use "ConfTest";
3281   for Object_Dir use ".";
3282   for Library_ALI_Dir use External("LIBRARY_DIR");
3283   for Library_Version use External ("SONAME");
3284   for Library_Kind use Kind;
3285   for Library_Dir use External("BUILD_DIR");
3286   Source_Dir := External ("SOURCE_DIR");
3287   for Source_Dirs use (Source_Dir);
3288 end Library;
3289 CF_EOF
3290                         cat >>confpackage.ads <<CF_EOF
3291 package ConfPackage is
3292    procedure conftest;
3293 end ConfPackage;
3294 CF_EOF
3295                         cat >>confpackage.adb <<CF_EOF
3296 with Text_IO;
3297 package body ConfPackage is
3298    procedure conftest is
3299    begin
3300       Text_IO.Put ("Hello World");
3301       Text_IO.New_Line;
3302    end conftest;
3303 end ConfPackage;
3304 CF_EOF
3305                         if ( "$cf_ada_make" $ADAFLAGS \
3306                                         -Plibrary.gpr \
3307                                         -XBUILD_DIR="`cd ../conftest.bin;pwd`" \
3308                                         -XLIBRARY_DIR="`cd ../conftest.lib;pwd`" \
3309                                         -XSOURCE_DIR="`pwd`" \
3310                                         -XSONAME=libConfTest.so.1 \
3311                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
3312                                 cf_gnat_projects=yes
3313                         fi
3314                         cd ..
3315                 fi
3316                 if test -f conftest.lib/confpackage.ali
3317                 then
3318                         cf_gnat_libraries=yes
3319                 fi
3320                 rm -rf ./conftest* ./*~conftest*
3321                 ;;
3322         esac
3323         ;;
3324 esac
3325 AC_MSG_RESULT($cf_gnat_projects)
3326 fi # enable_gnat_projects
3327
3328 if test "$cf_gnat_projects" = yes
3329 then
3330         AC_MSG_CHECKING(if GNAT supports libraries)
3331         AC_MSG_RESULT($cf_gnat_libraries)
3332 fi
3333
3334 USE_OLD_MAKERULES=""
3335 USE_GNAT_PROJECTS="#"
3336 USE_GNAT_MAKE_GPR="#"
3337 USE_GNAT_GPRBUILD="#"
3338
3339 if test "$cf_gnat_projects" = yes
3340 then
3341         USE_OLD_MAKERULES="#"
3342         USE_GNAT_PROJECTS=""
3343         if test "$cf_cv_VERSION_GPRBUILD" != no
3344         then
3345                 USE_GNAT_GPRBUILD=""
3346         elif test "$cf_cv_VERSION_GNATMAKE" != no
3347         then
3348                 USE_GNAT_MAKE_GPR=""
3349         else
3350                 AC_MSG_WARN(use old makefile rules since tools are missing)
3351         fi
3352 fi
3353
3354 if test "$cf_gnat_libraries" = yes
3355 then
3356         USE_GNAT_LIBRARIES=""
3357 else
3358         USE_GNAT_LIBRARIES="#"
3359 fi
3360
3361 AC_SUBST(USE_OLD_MAKERULES)
3362 AC_SUBST(USE_GNAT_PROJECTS)
3363 AC_SUBST(USE_GNAT_LIBRARIES)
3364 AC_SUBST(USE_GNAT_MAKE_GPR)
3365 AC_SUBST(USE_GNAT_GPRBUILD)
3366 ])dnl
3367 dnl ---------------------------------------------------------------------------
3368 dnl CF_GNAT_SIGINT version: 2 updated: 2021/01/01 13:31:04
3369 dnl --------------
3370 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
3371 dnl is noted that gnat may compile a tasking unit even for configurations which
3372 dnl fail at runtime.
3373 AC_DEFUN([CF_GNAT_SIGINT],[
3374 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
3375 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
3376
3377 package ConfTest is
3378
3379    pragma Warnings (Off);  --  the next pragma exists since 3.11p
3380    pragma Unreserve_All_Interrupts;
3381    pragma Warnings (On);
3382
3383    protected Process is
3384       procedure Stop;
3385       function Continue return Boolean;
3386       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
3387    private
3388       Done : Boolean := False;
3389    end Process;
3390
3391 end ConfTest;],
3392 [package body ConfTest is
3393    protected body Process is
3394       procedure Stop is
3395       begin
3396          Done := True;
3397       end Stop;
3398       function Continue return Boolean is
3399       begin
3400          return not Done;
3401       end Continue;
3402    end Process;
3403 end ConfTest;],
3404         [cf_cv_gnat_sigint=yes],
3405         [cf_cv_gnat_sigint=no])])
3406
3407 if test "$cf_cv_gnat_sigint" = yes ; then
3408         USE_GNAT_SIGINT=""
3409 else
3410         USE_GNAT_SIGINT="#"
3411 fi
3412 AC_SUBST(USE_GNAT_SIGINT)
3413 ])dnl
3414 dnl ---------------------------------------------------------------------------
3415 dnl CF_GNAT_TRY_LINK version: 4 updated: 2021/01/01 13:31:04
3416 dnl ----------------
3417 dnl Verify that a test program compiles/links with GNAT.
3418 dnl $cf_ada_make is set to the program that compiles/links
3419 dnl $ADAFLAGS may be set to the GNAT flags.
3420 dnl
3421 dnl $1 is the text of the spec
3422 dnl $2 is the text of the body
3423 dnl $3 is the shell command to execute if successful
3424 dnl $4 is the shell command to execute if not successful
3425 AC_DEFUN([CF_GNAT_TRY_LINK],
3426 [
3427 rm -rf ./conftest* ./*~conftest*
3428 cat >>conftest.ads <<CF_EOF
3429 $1
3430 CF_EOF
3431 cat >>conftest.adb <<CF_EOF
3432 $2
3433 CF_EOF
3434 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3435 ifelse($3,,      :,[      $3])
3436 ifelse($4,,,[else
3437    $4])
3438 fi
3439 rm -rf ./conftest* ./*~conftest*
3440 ])dnl
3441 dnl ---------------------------------------------------------------------------
3442 dnl CF_GNAT_TRY_RUN version: 6 updated: 2021/01/01 13:31:04
3443 dnl ---------------
3444 dnl Verify that a test program compiles and runs with GNAT
3445 dnl $cf_ada_make is set to the program that compiles/links
3446 dnl $ADAFLAGS may be set to the GNAT flags.
3447 dnl
3448 dnl $1 is the text of the spec
3449 dnl $2 is the text of the body
3450 dnl $3 is the shell command to execute if successful
3451 dnl $4 is the shell command to execute if not successful
3452 AC_DEFUN([CF_GNAT_TRY_RUN],
3453 [
3454 rm -rf ./conftest* ./*~conftest*
3455 cat >>conftest.ads <<CF_EOF
3456 $1
3457 CF_EOF
3458 cat >>conftest.adb <<CF_EOF
3459 $2
3460 CF_EOF
3461 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3462    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
3463 ifelse($3,,      :,[      $3])
3464 ifelse($4,,,[   else
3465       $4])
3466    fi
3467 ifelse($4,,,[else
3468    $4])
3469 fi
3470 rm -rf ./conftest* ./*~conftest*
3471 ])dnl
3472 dnl ---------------------------------------------------------------------------
3473 dnl CF_GNAT_VERSION version: 22 updated: 2019/12/31 08:53:54
3474 dnl ---------------
3475 dnl $1 = cache variable to update
3476 dnl $2 = program name
3477 dnl Verify version of GNAT or related tool
3478 AC_DEFUN([CF_GNAT_VERSION],
3479 [
3480 AC_CACHE_CHECK(for ifelse($2,,gnat,$2) version, cf_cv_gnat_version,[
3481 cf_cv_gnat_version=`ifelse($2,,${cf_ada_make:-gnatmake},$2) --version 2>&1 | \
3482         grep '[[0-9]].[[0-9]][[0-9]]*' |\
3483         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
3484 ])
3485 test -z "$cf_cv_gnat_version" && cf_cv_gnat_version=no
3486 ifelse($1,,,[eval $1=$cf_cv_gnat_version; unset cf_cv_gnat_version])
3487 ])dnl
3488 dnl ---------------------------------------------------------------------------
3489 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
3490 dnl -------------
3491 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
3492 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
3493 dnl (or misfeature) of glibc2, which breaks portability of many applications,
3494 dnl since it is interwoven with GNU extensions.
3495 dnl
3496 dnl Well, yes we could work around it...
3497 dnl
3498 dnl Parameters:
3499 dnl     $1 is the nominal value for _XOPEN_SOURCE
3500 AC_DEFUN([CF_GNU_SOURCE],
3501 [
3502 cf_gnu_xopen_source=ifelse($1,,500,$1)
3503
3504 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
3505 AC_TRY_COMPILE([#include <sys/types.h>],[
3506         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
3507                 return 0;
3508         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
3509                 return 0;
3510         #else
3511         #       error not GNU C library
3512         #endif],
3513         [cf_cv_gnu_library=yes],
3514         [cf_cv_gnu_library=no])
3515 ])
3516
3517 if test x$cf_cv_gnu_library = xyes; then
3518
3519         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
3520         # was changed to help a little.  newlib incorporated the change about 4
3521         # years later.
3522         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
3523                 cf_save="$CPPFLAGS"
3524                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3525                 AC_TRY_COMPILE([#include <sys/types.h>],[
3526                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
3527                                 return 0;
3528                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
3529                                 return 0;
3530                         #else
3531                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
3532                         #endif],
3533                         [cf_cv_gnu_library_219=yes],
3534                         [cf_cv_gnu_library_219=no])
3535                 CPPFLAGS="$cf_save"
3536         ])
3537
3538         if test "x$cf_cv_gnu_library_219" = xyes; then
3539                 cf_save="$CPPFLAGS"
3540                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
3541                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
3542                         AC_TRY_COMPILE([
3543                                 #include <limits.h>
3544                                 #include <sys/types.h>
3545                                 ],[
3546                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
3547                                         return 0;
3548                                 #else
3549                                 #       error GNU C library is too old
3550                                 #endif],
3551                                 [cf_cv_gnu_dftsrc_219=yes],
3552                                 [cf_cv_gnu_dftsrc_219=no])
3553                         ])
3554                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
3555         else
3556                 cf_cv_gnu_dftsrc_219=maybe
3557         fi
3558
3559         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
3560
3561                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
3562                 AC_TRY_COMPILE([#include <sys/types.h>],[
3563                         #ifndef _XOPEN_SOURCE
3564                         #error  expected _XOPEN_SOURCE to be defined
3565                         #endif],
3566                         [cf_cv_gnu_source=no],
3567                         [cf_save="$CPPFLAGS"
3568                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
3569                          AC_TRY_COMPILE([#include <sys/types.h>],[
3570                                 #ifdef _XOPEN_SOURCE
3571                                 #error  expected _XOPEN_SOURCE to be undefined
3572                                 #endif],
3573                                 [cf_cv_gnu_source=no],
3574                                 [cf_cv_gnu_source=yes])
3575                         CPPFLAGS="$cf_save"
3576                         ])
3577                 ])
3578
3579                 if test "$cf_cv_gnu_source" = yes
3580                 then
3581                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
3582                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
3583                         AC_TRY_COMPILE([#include <sys/types.h>],[
3584                                 #ifdef _DEFAULT_SOURCE
3585                                 #error  expected _DEFAULT_SOURCE to be undefined
3586                                 #endif],
3587                                 [cf_cv_default_source=no],
3588                                 [cf_cv_default_source=yes])
3589                         ])
3590                         if test "$cf_cv_default_source" = yes
3591                         then
3592                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3593                         fi
3594                 fi
3595         fi
3596
3597 fi
3598 ])dnl
3599 dnl ---------------------------------------------------------------------------
3600 dnl CF_GPP_LIBRARY version: 13 updated: 2021/01/01 13:31:04
3601 dnl --------------
3602 dnl If we're trying to use g++, test if libg++ is installed (a rather common
3603 dnl problem :-).  If we have the compiler but no library, we'll be able to
3604 dnl configure, but won't be able to build the c++ demo program.
3605 AC_DEFUN([CF_GPP_LIBRARY],
3606 [
3607 cf_cxx_library=unknown
3608 case "$cf_cv_system_name" in
3609 (os2*)
3610         cf_gpp_libname=gpp
3611         ;;
3612 (*)
3613         cf_gpp_libname=g++
3614         ;;
3615 esac
3616 if test "$GXX" = yes; then
3617         AC_MSG_CHECKING([for lib$cf_gpp_libname])
3618         cf_save="$LIBS"
3619         CF_ADD_LIB($cf_gpp_libname)
3620         AC_TRY_LINK([
3621 #include <$cf_gpp_libname/builtin.h>
3622         ],
3623         [two_arg_error_handler_t foo2 = lib_error_handler],
3624         [cf_cxx_library=yes
3625          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3626          if test "$cf_gpp_libname" = cpp ; then
3627             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
3628          else
3629             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
3630          fi],
3631         [AC_TRY_LINK([
3632 #include <builtin.h>
3633         ],
3634         [two_arg_error_handler_t foo2 = lib_error_handler],
3635         [cf_cxx_library=yes
3636          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3637          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
3638         [cf_cxx_library=no])])
3639         LIBS="$cf_save"
3640         AC_MSG_RESULT($cf_cxx_library)
3641 fi
3642 ])dnl
3643 dnl ---------------------------------------------------------------------------
3644 dnl CF_GXX_VERSION version: 9 updated: 2023/03/05 14:30:13
3645 dnl --------------
3646 dnl Check for version of g++
3647 AC_DEFUN([CF_GXX_VERSION],[
3648 AC_REQUIRE([AC_PROG_CPP])
3649 GXX_VERSION=none
3650 if test "$GXX" = yes; then
3651         AC_MSG_CHECKING(version of ${CXX:-g++})
3652         GXX_VERSION="`${CXX:-g++} --version 2>/dev/null | sed -e '2,$d' -e 's/^[[^(]]*([[^)]][[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
3653         if test -z "$GXX_VERSION"
3654         then
3655                 GXX_VERSION=unknown
3656                 GXX=no
3657         fi
3658         AC_MSG_RESULT($GXX_VERSION)
3659 fi
3660 ])dnl
3661 dnl ---------------------------------------------------------------------------
3662 dnl CF_GXX_WARNINGS version: 11 updated: 2021/01/08 16:50:55
3663 dnl ---------------
3664 dnl Check if the compiler supports useful warning options.
3665 dnl
3666 dnl Most of gcc's options apply to g++, except:
3667 dnl     -Wbad-function-cast
3668 dnl     -Wmissing-declarations
3669 dnl     -Wnested-externs
3670 dnl
3671 dnl Omit a few (for now):
3672 dnl     -Winline
3673 dnl
3674 dnl Parameter:
3675 dnl     $1 is an optional list of g++ warning flags that a particular
3676 dnl             application might want to use, e.g., "no-unused" for
3677 dnl             -Wno-unused
3678 dnl Special:
3679 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
3680 dnl
3681 AC_DEFUN([CF_GXX_WARNINGS],
3682 [
3683
3684 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
3685 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
3686
3687 AC_REQUIRE([CF_GXX_VERSION])
3688
3689 AC_LANG_SAVE
3690 AC_LANG_CPLUSPLUS
3691
3692 cat > conftest.$ac_ext <<EOF
3693 #line __oline__ "configure"
3694 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
3695 EOF
3696
3697 if test "$INTEL_CPLUSPLUS" = yes
3698 then
3699 # The "-wdXXX" options suppress warnings:
3700 # remark #1419: external declaration in primary source file
3701 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3702 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3703 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
3704 # remark #193: zero used for undefined preprocessing identifier
3705 # remark #593: variable "curs_sb_left_arrow" was set but never used
3706 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
3707 # remark #869: parameter "tw" was never referenced
3708 # remark #981: operands are evaluated in unspecified order
3709 # warning #269: invalid format string conversion
3710
3711         AC_CHECKING([for $CC warning options])
3712         cf_save_CXXFLAGS="$CXXFLAGS"
3713         EXTRA_CXXFLAGS="-Wall"
3714         for cf_opt in \
3715                 wd1419 \
3716                 wd1682 \
3717                 wd1683 \
3718                 wd1684 \
3719                 wd193 \
3720                 wd279 \
3721                 wd593 \
3722                 wd810 \
3723                 wd869 \
3724                 wd981
3725         do
3726                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
3727                 if AC_TRY_EVAL(ac_compile); then
3728                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3729                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3730                 fi
3731         done
3732         CXXFLAGS="$cf_save_CXXFLAGS"
3733
3734 elif test "$GXX" = yes
3735 then
3736         AC_CHECKING([for $CXX warning options])
3737         cf_save_CXXFLAGS="$CXXFLAGS"
3738         EXTRA_CXXFLAGS="-W -Wall"
3739         cf_gxx_extra_warnings=""
3740         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
3741         case "$GXX_VERSION" in
3742         ([[1-2]].*)
3743                 ;;
3744         (*)
3745                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
3746                 ;;
3747         esac
3748         for cf_opt in \
3749                 Wabi \
3750                 fabi-version=0 \
3751                 Wextra \
3752                 Wignored-qualifiers \
3753                 Wlogical-op \
3754                 Woverloaded-virtual \
3755                 Wsign-promo \
3756                 Wsynth \
3757                 Wold-style-cast \
3758                 Wcast-align \
3759                 Wcast-qual \
3760                 Wpointer-arith \
3761                 Wshadow \
3762                 Wundef $cf_gxx_extra_warnings $1
3763         do
3764                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
3765                 if AC_TRY_EVAL(ac_compile); then
3766                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3767                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3768                 else
3769                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
3770                 fi
3771         done
3772         CXXFLAGS="$cf_save_CXXFLAGS"
3773 fi
3774
3775 rm -rf ./conftest*
3776 AC_LANG_RESTORE
3777 AC_SUBST(EXTRA_CXXFLAGS)
3778 ])dnl
3779 dnl ---------------------------------------------------------------------------
3780 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
3781 dnl ------------
3782 dnl Look for an instance of the Berkeley hashed database.
3783 dnl
3784 dnl $1 = optional parameter, to specify install-prefix for the database.
3785 AC_DEFUN([CF_HASHED_DB],
3786 [
3787 ifelse([$1],,,[
3788 case $1 in
3789 (yes|*able*)
3790         ;;
3791 (*)
3792         if test -d "$1" ; then
3793                 CF_ADD_INCDIR($1/include)
3794                 CF_ADD_LIBDIR($1/lib)
3795         else
3796                 case "$1" in
3797                 (./*|../*|/*)
3798                         AC_MSG_WARN(no such directory $1)
3799                         ;;
3800                 (*)
3801                         CF_FIND_SUB_INCDIR($1)
3802                         CF_FIND_SUB_LIBDIR($1)
3803                         ;;
3804                 esac
3805         fi
3806 esac
3807 ])
3808 AC_CHECK_HEADER(db.h,[
3809 CF_HASHED_DB_VERSION
3810 if test "$cf_cv_hashed_db_version" = unknown ; then
3811         AC_MSG_ERROR(Cannot determine version of db)
3812 else
3813         CF_HASHED_DB_LIBS
3814         if test "$cf_cv_hashed_db_libs" = unknown ; then
3815                 AC_MSG_ERROR(Cannot determine library for db)
3816         elif test "$cf_cv_hashed_db_libs" != default ; then
3817                 CF_ADD_LIB($cf_cv_hashed_db_libs)
3818         fi
3819 fi
3820 ],[
3821         AC_MSG_ERROR(Cannot find db.h)
3822 ])
3823 ])dnl
3824 dnl ---------------------------------------------------------------------------
3825 dnl CF_HASHED_DB_LIBS version: 10 updated: 2021/01/02 17:09:14
3826 dnl -----------------
3827 dnl Given that we have the header and version for hashed database, find the
3828 dnl library information.
3829 AC_DEFUN([CF_HASHED_DB_LIBS],
3830 [
3831 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
3832 cf_cv_hashed_db_libs=unknown
3833 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
3834 do
3835         cf_save_libs="$LIBS"
3836         if test -n "$cf_db_libs"; then
3837                 CF_ADD_LIB($cf_db_libs)
3838         fi
3839         CF_MSG_LOG(checking for library $cf_db_libs)
3840         AC_TRY_LINK([
3841 $ac_includes_default
3842 #include <db.h>
3843 ],[
3844         char *path = "/tmp/foo";
3845 #ifdef DB_VERSION_MAJOR
3846 #if DB_VERSION_MAJOR >= 4
3847         DB *result = 0;
3848         db_create(&result, NULL, 0);
3849         result->open(result,
3850                 NULL,
3851                 path,
3852                 path,
3853                 DB_HASH,
3854                 DB_CREATE,
3855                 0644);
3856 #elif DB_VERSION_MAJOR >= 3
3857         DB *result = 0;
3858         db_create(&result, NULL, 0);
3859         result->open(result,
3860                 path,
3861                 path,
3862                 DB_HASH,
3863                 DB_CREATE,
3864                 0644);
3865 #elif DB_VERSION_MAJOR >= 2
3866         DB *result = 0;
3867         db_open(path,
3868                 DB_HASH,
3869                 DB_CREATE,
3870                 0644,
3871                 (DB_ENV *) 0,
3872                 (DB_INFO *) 0,
3873                 &result);
3874 #endif /* DB_VERSION_MAJOR */
3875 #else
3876         DB *result = dbopen(path,
3877                      2,
3878                      0644,
3879                      DB_HASH,
3880                      0);
3881 #endif
3882         ${cf_cv_main_return:-return}(result != 0)
3883 ],[
3884         if test -n "$cf_db_libs" ; then
3885                 cf_cv_hashed_db_libs=$cf_db_libs
3886         else
3887                 cf_cv_hashed_db_libs=default
3888         fi
3889         LIBS="$cf_save_libs"
3890         break
3891 ])
3892         LIBS="$cf_save_libs"
3893 done
3894 ])
3895 ])dnl
3896 dnl ---------------------------------------------------------------------------
3897 dnl CF_HASHED_DB_VERSION version: 5 updated: 2023/02/18 17:41:25
3898 dnl --------------------
3899 dnl Given that we have the header file for hashed database, find the version
3900 dnl information.
3901 AC_DEFUN([CF_HASHED_DB_VERSION],
3902 [
3903 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3904 cf_cv_hashed_db_version=unknown
3905
3906 for cf_db_version in 1 2 3 4 5 6
3907 do
3908         CF_MSG_LOG(checking for db version $cf_db_version)
3909         AC_TRY_COMPILE([
3910 $ac_includes_default
3911 #include <db.h>
3912
3913 #ifdef DB_VERSION_MAJOR
3914         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3915 #if $cf_db_version == DB_VERSION_MAJOR
3916         /* ok */
3917 #else
3918         #error $cf_db_version is not DB_VERSION_MAJOR
3919 #endif
3920 #else
3921 #if $cf_db_version == 1
3922         /* ok: assuming this is DB 1.8.5 */
3923 #else
3924         #error $cf_db_version is not 1
3925 #endif
3926 #endif
3927 ],[DBT *foo = 0],[
3928         cf_cv_hashed_db_version=$cf_db_version
3929         break
3930         ])
3931 done
3932 ])
3933 ])dnl
3934 dnl ---------------------------------------------------------------------------
3935 dnl CF_HEADER_PATH version: 15 updated: 2021/01/01 13:31:04
3936 dnl --------------
3937 dnl Construct a search-list of directories for a nonstandard header-file
3938 dnl
3939 dnl Parameters
3940 dnl     $1 = the variable to return as result
3941 dnl     $2 = the package name
3942 AC_DEFUN([CF_HEADER_PATH],
3943 [
3944 $1=
3945
3946 # collect the current set of include-directories from compiler flags
3947 cf_header_path_list=""
3948 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3949         for cf_header_path in $CPPFLAGS $CFLAGS
3950         do
3951                 case "$cf_header_path" in
3952                 (-I*)
3953                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3954                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3955                         cf_header_path_list="$cf_header_path_list [$]$1"
3956                         ;;
3957                 esac
3958         done
3959 fi
3960
3961 # add the variations for the package we are looking for
3962 CF_SUBDIR_PATH($1,$2,include)
3963
3964 test "$includedir" != NONE && \
3965 test "$includedir" != "/usr/include" && \
3966 test -d "$includedir" && {
3967         test -d "$includedir" &&    $1="[$]$1 $includedir"
3968         test -d "$includedir/$2" && $1="[$]$1 $includedir/$2"
3969 }
3970
3971 test "$oldincludedir" != NONE && \
3972 test "$oldincludedir" != "/usr/include" && \
3973 test -d "$oldincludedir" && {
3974         test -d "$oldincludedir"    && $1="[$]$1 $oldincludedir"
3975         test -d "$oldincludedir/$2" && $1="[$]$1 $oldincludedir/$2"
3976 }
3977
3978 $1="[$]$1 $cf_header_path_list"
3979 ])dnl
3980 dnl ---------------------------------------------------------------------------
3981 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
3982 dnl ---------------
3983 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3984 AC_DEFUN([CF_HELP_MESSAGE],
3985 [CF_ACVERSION_CHECK(2.53,[],[
3986 AC_DIVERT_HELP($1)])dnl
3987 ])dnl
3988 dnl ---------------------------------------------------------------------------
3989 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3990 dnl ---------------
3991 dnl Construct the list of include-options according to whether we're building
3992 dnl in the source directory or using '--srcdir=DIR' option.
3993 AC_DEFUN([CF_INCLUDE_DIRS],
3994 [
3995 if test "$srcdir" != "."; then
3996         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3997 fi
3998 CPPFLAGS="-I../include $CPPFLAGS"
3999 if test "$srcdir" != "."; then
4000         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
4001 fi
4002 CPPFLAGS="-I. $CPPFLAGS"
4003 AC_SUBST(CPPFLAGS)
4004 ])dnl
4005 dnl ---------------------------------------------------------------------------
4006 dnl CF_INSTALL_OPTS version: 3 updated: 2023/06/03 15:17:30
4007 dnl ---------------
4008 dnl prompt for/fill-in useful install-program options
4009 AC_DEFUN([CF_INSTALL_OPTS],
4010 [
4011 CF_INSTALL_OPT_S
4012 CF_INSTALL_OPT_P
4013 CF_INSTALL_OPT_O
4014 CF_INSTALL_OPT_STRIP_PROG
4015 ])dnl
4016 dnl ---------------------------------------------------------------------------
4017 dnl CF_INSTALL_OPT_O version: 3 updated: 2020/12/31 20:19:42
4018 dnl ----------------
4019 dnl Almost all "install" programs default to the current user's ownership.
4020 dnl Almost - MINIX is an exception.
4021 AC_DEFUN([CF_INSTALL_OPT_O],
4022 [
4023 AC_MSG_CHECKING(if install needs to be told about ownership)
4024 case `$ac_config_guess` in
4025 (*minix)
4026         with_install_o=yes
4027         ;;
4028 (*)
4029         with_install_o=no
4030         ;;
4031 esac
4032
4033 AC_MSG_RESULT($with_install_o)
4034 if test "x$with_install_o" = xyes
4035 then
4036         INSTALL_OPT_O="`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`"
4037 else
4038         INSTALL_OPT_O=
4039 fi
4040
4041 AC_SUBST(INSTALL_OPT_O)
4042 ])dnl
4043 dnl ---------------------------------------------------------------------------
4044 dnl CF_INSTALL_OPT_P version: 3 updated: 2021/01/01 13:31:04
4045 dnl ----------------
4046 dnl Some install-programs accept a "-p" option to preserve file modification
4047 dnl timestamps.  That can be useful as an install option, as well as a way to
4048 dnl avoid the need for ranlib after copying a static archive.
4049 AC_DEFUN([CF_INSTALL_OPT_P],
4050 [
4051 : "${INSTALL:=install}"
4052 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
4053         rm -rf ./conftest*
4054         date >conftest.in
4055         mkdir conftest.out
4056         sleep 3
4057         if $INSTALL -p conftest.in conftest.out 2>/dev/null
4058         then
4059                 if test -f conftest.out/conftest.in
4060                 then
4061                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
4062                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
4063                         if test -s conftest.err
4064                         then
4065                                 cf_cv_install_p=no
4066                         else
4067                                 cf_cv_install_p=yes
4068                         fi
4069                 else
4070                         cf_cv_install_p=no
4071                 fi
4072         else
4073                 cf_cv_install_p=no
4074         fi
4075         rm -rf ./conftest*
4076 ])
4077 ])dnl
4078 dnl ---------------------------------------------------------------------------
4079 dnl CF_INSTALL_OPT_S version: 3 updated: 2021/01/05 19:23:48
4080 dnl ----------------
4081 dnl By default, we should strip executables which are installed, but leave the
4082 dnl ability to suppress that for unit-testing.
4083 AC_DEFUN([CF_INSTALL_OPT_S],
4084 [
4085 AC_MSG_CHECKING(if you want to install stripped executables)
4086 CF_ARG_DISABLE(stripping,
4087         [  --disable-stripping     do not strip (debug info) installed executables],
4088         [enable_stripping=no],
4089         [enable_stripping=yes])
4090 AC_MSG_RESULT($enable_stripping)
4091
4092 if test "$enable_stripping" = yes
4093 then
4094         INSTALL_OPT_S="-s"
4095 else
4096         INSTALL_OPT_S=
4097 fi
4098 AC_SUBST(INSTALL_OPT_S)
4099 ])dnl
4100 dnl ---------------------------------------------------------------------------
4101 dnl CF_INSTALL_OPT_STRIP_PROG version: 1 updated: 2023/06/03 15:17:30
4102 dnl -------------------------
4103 dnl Provide an option for overriding the strip program used in install "-s"
4104 dnl
4105 dnl coreutils install provides a --strip-program option
4106 dnl FreeBSD uses STRIPBIN environment variable, while NetBSD and OpenBSD use
4107 dnl STRIP environment variable.  Other versions of install do not support this.
4108 AC_DEFUN([CF_INSTALL_OPT_STRIP_PROG],
4109 [
4110 AC_REQUIRE([CF_INSTALL_OPT_S])
4111 if test -n "$INSTALL_OPT_S"
4112 then
4113         AC_MSG_CHECKING(if you want to specify strip-program)
4114         AC_ARG_WITH(strip-program,
4115                 [  --with-strip-program=XX specify program to use when stripping in install],
4116                 [with_strip_program=$withval],
4117                 [with_strip_program=no])
4118         AC_MSG_RESULT($with_strip_program)
4119         if test "$with_strip_program" != no
4120         then
4121                 AC_MSG_CHECKING(if strip-program is supported with this installer)
4122                 cf_install_program=`echo "$INSTALL" | sed -e 's%[[ ]]*[[ ]]-.%%'`
4123                 check_install_strip=no
4124                 if test -f "$cf_install_program"
4125                 then
4126                         check_install_version=`"$cf_install_program" --version 2>/dev/null | head -n 1 | grep coreutils`
4127                         if test -n "$check_install_version"
4128                         then
4129                                 check_install_strip="option"
4130                         else
4131                                 for check_strip_variable in STRIPBIN STRIP
4132                                 do
4133                                         if strings "$cf_install_program" | grep "^$check_strip_variable[$]" >/dev/null
4134                                         then
4135                                                 check_install_strip="environ"
4136                                                 break
4137                                         fi
4138                                 done
4139                         fi
4140                 fi
4141                 AC_MSG_RESULT($check_install_strip)
4142                 case "$check_install_strip" in
4143                 (no)
4144                         AC_MSG_WARN($cf_install_program does not support strip program option)
4145                         with_strip_program=no
4146                         ;;
4147                 (environ)
4148                         cat >install.tmp <<-CF_EOF
4149                         #! $SHELL
4150                         STRIPBIN="$with_strip_program" \\
4151                         STRIP="$with_strip_program" \\
4152                         $INSTALL "[$]@"
4153                         CF_EOF
4154                         INSTALL="`pwd`/install.tmp"
4155                         chmod +x "$INSTALL"
4156                         CF_VERBOSE(created $INSTALL)
4157                         ;;
4158                 (option)
4159                         INSTALL_OPT_S="$INSTALL_OPT_S --strip-program=\"$with_strip_program\""
4160                         ;;
4161                 esac
4162         fi
4163 fi
4164 AC_SUBST(INSTALL_OPT_S)
4165 ])dnl
4166 dnl ---------------------------------------------------------------------------
4167 dnl CF_INTEL_COMPILER version: 9 updated: 2023/02/18 17:41:25
4168 dnl -----------------
4169 dnl Check if the given compiler is really the Intel compiler for Linux.  It
4170 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
4171 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
4172 dnl
4173 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
4174 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
4175 dnl the wrappers for gcc and g++ warnings.
4176 dnl
4177 dnl $1 = GCC (default) or GXX
4178 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
4179 dnl $3 = CFLAGS (default) or CXXFLAGS
4180 AC_DEFUN([CF_INTEL_COMPILER],[
4181 AC_REQUIRE([AC_CANONICAL_HOST])
4182 ifelse([$2],,INTEL_COMPILER,[$2])=no
4183
4184 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
4185         case "$host_os" in
4186         (linux*|gnu*)
4187                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
4188                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
4189                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
4190                 AC_TRY_COMPILE([],[
4191 #ifdef __INTEL_COMPILER
4192 #else
4193 #error __INTEL_COMPILER is not defined
4194 #endif
4195 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
4196 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
4197 ],[])
4198                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
4199                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
4200                 ;;
4201         esac
4202 fi
4203 ])dnl
4204 dnl ---------------------------------------------------------------------------
4205 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
4206 dnl ----------
4207 dnl Check if we have either a function or macro for 'isascii()'.
4208 AC_DEFUN([CF_ISASCII],
4209 [
4210 AC_MSG_CHECKING(for isascii)
4211 AC_CACHE_VAL(cf_cv_have_isascii,[
4212         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
4213         [cf_cv_have_isascii=yes],
4214         [cf_cv_have_isascii=no])
4215 ])dnl
4216 AC_MSG_RESULT($cf_cv_have_isascii)
4217 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
4218 ])dnl
4219 dnl ---------------------------------------------------------------------------
4220 dnl CF_LARGEFILE version: 12 updated: 2020/03/19 20:23:48
4221 dnl ------------
4222 dnl Add checks for large file support.
4223 AC_DEFUN([CF_LARGEFILE],[
4224 ifdef([AC_FUNC_FSEEKO],[
4225         AC_SYS_LARGEFILE
4226         if test "$enable_largefile" != no ; then
4227         AC_FUNC_FSEEKO
4228
4229         # Normally we would collect these definitions in the config.h,
4230         # but (like _XOPEN_SOURCE), some environments rely on having these
4231         # defined before any of the system headers are included.  Another
4232         # case comes up with C++, e.g., on AIX the compiler compiles the
4233         # header files by themselves before looking at the body files it is
4234         # told to compile.  For ncurses, those header files do not include
4235         # the config.h
4236         if test "$ac_cv_sys_large_files" != no
4237         then
4238                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
4239         fi
4240         if test "$ac_cv_sys_largefile_source" != no
4241         then
4242                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
4243         fi
4244         if test "$ac_cv_sys_file_offset_bits" != no
4245         then
4246                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
4247         fi
4248
4249         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
4250                 AC_TRY_COMPILE([
4251 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
4252 #include <sys/types.h>
4253 #include <dirent.h>
4254                 ],[
4255                 /* if transitional largefile support is setup, this is true */
4256                 extern struct dirent64 * readdir(DIR *);
4257                 struct dirent64 *x = readdir((DIR *)0);
4258                 struct dirent *y = readdir((DIR *)0);
4259                 int z = x - y;
4260                 (void)z;
4261                 ],
4262                 [cf_cv_struct_dirent64=yes],
4263                 [cf_cv_struct_dirent64=no])
4264         ])
4265         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
4266         fi
4267 ])
4268 ])
4269 dnl ---------------------------------------------------------------------------
4270 dnl CF_LDFLAGS_STATIC version: 14 updated: 2021/01/02 17:09:14
4271 dnl -----------------
4272 dnl Check for compiler/linker flags used to temporarily force usage of static
4273 dnl libraries.  This depends on the compiler and platform.  Use this to help
4274 dnl ensure that the linker picks up a given library based on its position in
4275 dnl the list of linker options and libraries.
4276 AC_DEFUN([CF_LDFLAGS_STATIC],[
4277
4278 if test "$GCC" = yes ; then
4279         case "$cf_cv_system_name" in
4280         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
4281                 LDFLAGS_STATIC=
4282                 LDFLAGS_SHARED=
4283                 ;;
4284         (*)     # normally, except when broken
4285                 LDFLAGS_STATIC=-static
4286                 LDFLAGS_SHARED=-dynamic
4287                 ;;
4288         esac
4289 else
4290         case "$cf_cv_system_name" in
4291         (aix[[4-7]]*)   # from ld manpage
4292                 LDFLAGS_STATIC=-bstatic
4293                 LDFLAGS_SHARED=-bdynamic
4294                 ;;
4295         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
4296                 # We could also use just "archive" and "shared".
4297                 LDFLAGS_STATIC=-Wl,-a,archive_shared
4298                 LDFLAGS_SHARED=-Wl,-a,shared_archive
4299                 ;;
4300         (irix*)         # from ld manpage IRIX64
4301                 LDFLAGS_STATIC=-Bstatic
4302                 LDFLAGS_SHARED=-Bdynamic
4303                 ;;
4304         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
4305                 # alternative "-oldstyle_liblookup" (not in cc manpage)
4306                 LDFLAGS_STATIC=-noso
4307                 LDFLAGS_SHARED=-so_archive
4308                 ;;
4309         (solaris2*)
4310                 LDFLAGS_STATIC=-Bstatic
4311                 LDFLAGS_SHARED=-Bdynamic
4312                 ;;
4313         esac
4314 fi
4315
4316 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
4317 then
4318         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
4319
4320         rm -f libconftest.a
4321         cat >conftest.$ac_ext <<EOF
4322 #line __oline__ "configure"
4323 #include <stdio.h>
4324 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
4325 EOF
4326         if AC_TRY_EVAL(ac_compile) ; then
4327                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
4328                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
4329         fi
4330         rm -f conftest.*
4331
4332         cf_save_LIBS="$LIBS"
4333
4334         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
4335         AC_TRY_LINK([
4336 #line __oline__ "configure"
4337 #include <stdio.h>
4338 int cf_ldflags_static(FILE *fp);
4339 ],[
4340         return cf_ldflags_static(stdin);
4341 ],[
4342         # some linkers simply ignore the -dynamic
4343         case x`file "conftest$ac_exeext" 2>/dev/null` in
4344         (*static*)
4345                 cf_ldflags_static=no
4346                 ;;
4347         (*)
4348                 cf_ldflags_static=yes
4349                 ;;
4350         esac
4351 ],[cf_ldflags_static=no])
4352
4353         rm -f libconftest.*
4354         LIBS="$cf_save_LIBS"
4355
4356         AC_MSG_RESULT($cf_ldflags_static)
4357
4358         if test "$cf_ldflags_static" != yes
4359         then
4360                 LDFLAGS_STATIC=
4361                 LDFLAGS_SHARED=
4362         fi
4363 else
4364         LDFLAGS_STATIC=
4365         LDFLAGS_SHARED=
4366 fi
4367
4368 AC_SUBST(LDFLAGS_STATIC)
4369 AC_SUBST(LDFLAGS_SHARED)
4370 ])
4371 dnl ---------------------------------------------------------------------------
4372 dnl CF_LD_RPATH_OPT version: 9 updated: 2021/01/01 13:31:04
4373 dnl ---------------
4374 dnl For the given system and compiler, find the compiler flags to pass to the
4375 dnl loader to use the "rpath" feature.
4376 AC_DEFUN([CF_LD_RPATH_OPT],
4377 [
4378 AC_REQUIRE([CF_CHECK_CACHE])
4379
4380 LD_RPATH_OPT=
4381 if test "x$cf_cv_enable_rpath" != xno
4382 then
4383         AC_MSG_CHECKING(for an rpath option)
4384         case "$cf_cv_system_name" in
4385         (irix*)
4386                 if test "$GCC" = yes; then
4387                         LD_RPATH_OPT="-Wl,-rpath,"
4388                 else
4389                         LD_RPATH_OPT="-rpath "
4390                 fi
4391                 ;;
4392         (linux*|gnu*|k*bsd*-gnu|freebsd*)
4393                 LD_RPATH_OPT="-Wl,-rpath,"
4394                 ;;
4395         (openbsd[[2-9]].*|mirbsd*)
4396                 LD_RPATH_OPT="-Wl,-rpath,"
4397                 ;;
4398         (dragonfly*)
4399                 LD_RPATH_OPT="-rpath "
4400                 ;;
4401         (netbsd*)
4402                 LD_RPATH_OPT="-Wl,-rpath,"
4403                 ;;
4404         (osf*|mls+*)
4405                 LD_RPATH_OPT="-rpath "
4406                 ;;
4407         (solaris2*)
4408                 LD_RPATH_OPT="-R"
4409                 ;;
4410         (*)
4411                 ;;
4412         esac
4413         AC_MSG_RESULT($LD_RPATH_OPT)
4414
4415         case "x$LD_RPATH_OPT" in
4416         (x-R*)
4417                 AC_MSG_CHECKING(if we need a space after rpath option)
4418                 cf_save_LIBS="$LIBS"
4419                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
4420                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
4421                 LIBS="$cf_save_LIBS"
4422                 AC_MSG_RESULT($cf_rpath_space)
4423                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
4424                 ;;
4425         esac
4426 fi
4427 ])dnl
4428 dnl ---------------------------------------------------------------------------
4429 dnl CF_LD_SEARCHPATH version: 4 updated: 2022/08/27 15:43:08
4430 dnl ----------------
4431 dnl Try to obtain the linker's search-path, for use in scripts.
4432 dnl
4433 dnl Ignore LD_LIBRARY_PATH, etc.
4434 AC_DEFUN([CF_LD_SEARCHPATH],[
4435 AC_CACHE_CHECK(for linker search path,cf_cv_ld_searchpath,[
4436
4437 if test "$cross_compiling" != yes ; then
4438
4439 # GNU binutils' ld does not involve permissions which may stop ldconfig.
4440 cf_pathlist=`${LD:-ld} --verbose 2>/dev/null | grep SEARCH_DIR | sed -e 's,SEARCH_DIR[[("=]][[("=]]*,,g' -e 's/"[[)]];//gp' | sort -u`
4441
4442 # The -NX options tell newer versions of Linux ldconfig to not attempt to
4443 # update the cache, which makes it run faster.
4444 test -z "$cf_pathlist" && \
4445         cf_pathlist=`(ldconfig -NX -v) 2>/dev/null | sed -e '/^[[       ]]/d' -e 's/:$//' | sort -u`
4446
4447 test -z "$cf_pathlist" &&
4448         cf_pathlist=`(ldconfig -v) 2>/dev/null | sed -n -e '/^[[        ]]/d' -e 's/:$//p' | sort -u`
4449
4450 # This works with OpenBSD 6.5, which lists only filenames
4451 test -z "$cf_pathlist" &&
4452         cf_pathlist=`(ldconfig -v) 2>/dev/null | sed -n -e 's,^Adding \(.*\)/.*[$],\1,p' | sort -u`
4453
4454 if test -z "$cf_pathlist"
4455 then
4456         # dyld default path with MacOS
4457         if test -f /usr/bin/otool && test "x`uname -s`" = xDarwin
4458         then
4459                 # do this to bypass check
4460                 cf_cv_ld_searchpath='$HOME/lib'
4461                 cf_pathlist="/usr/local/lib /lib /usr/lib"
4462         fi
4463 fi
4464
4465 if test -z "$cf_pathlist"
4466 then
4467         # Solaris is "SunOS"
4468         if test -f /usr/bin/isainfo && test "x`uname -s`" = xSunOS
4469         then
4470                 case x`(isainfo -b)` in
4471                 (x64)
4472                         cf_pathlist="$cf_pathlist /lib/64 /usr/lib/64"
4473                         ;;
4474                 (x32)
4475                         test -d /usr/ccs/lib && cf_pathlist="$cf_pathlist /usr/ccs/lib"
4476                         cf_pathlist="$cf_pathlist /lib /usr/lib"
4477                         ;;
4478                 (*)
4479                         AC_MSG_WARN(problem with Solaris architecture)
4480                         ;;
4481                 esac
4482         fi
4483 fi
4484
4485 if test -z "$cf_pathlist"
4486 then
4487         # HP-UX
4488         if test x"`uname -s`" = xHP-UX
4489         then
4490                 case x`getconf LONG_BIT` in
4491                 (x64)
4492                         cf_pathlist="/usr/lib/hpux64"
4493                         ;;
4494                 (x*)
4495                         cf_pathlist="/usr/lib/hpux32"
4496                         ;;
4497                 esac
4498         fi
4499 fi
4500
4501 fi
4502
4503 # If nothing else, assume it is conventional
4504 test -z "$cf_pathlist" && cf_pathlist="/usr/lib /lib"
4505
4506 # Finally, check that this is only directories
4507 for cf_path in [$]0 $cf_pathlist
4508 do
4509         if test -d "$cf_path"; then
4510                 test -n "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath="${cf_cv_ld_searchpath} "
4511                 cf_cv_ld_searchpath="${cf_cv_ld_searchpath}${cf_path}"
4512         fi
4513 done
4514
4515 # Ensure that it is nonempty
4516 test -z "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath=/usr/lib
4517 ])
4518
4519 LD_SEARCHPATH=`echo "$cf_cv_ld_searchpath"|sed -e 's/ /|/g'`
4520 AC_SUBST(LD_SEARCHPATH)
4521 ])dnl
4522 dnl ---------------------------------------------------------------------------
4523 dnl CF_LIBRARY_PATH version: 11 updated: 2021/01/01 13:31:04
4524 dnl ---------------
4525 dnl Construct a search-list of directories for a nonstandard library-file
4526 dnl
4527 dnl Parameters
4528 dnl     $1 = the variable to return as result
4529 dnl     $2 = the package name
4530 AC_DEFUN([CF_LIBRARY_PATH],
4531 [
4532 $1=
4533 cf_library_path_list=""
4534 if test -n "${LDFLAGS}${LIBS}" ; then
4535         for cf_library_path in $LDFLAGS $LIBS
4536         do
4537                 case "$cf_library_path" in
4538                 (-L*)
4539                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
4540                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
4541                         cf_library_path_list="$cf_library_path_list [$]$1"
4542                         ;;
4543                 esac
4544         done
4545 fi
4546
4547 CF_SUBDIR_PATH($1,$2,lib)
4548
4549 $1="$cf_library_path_list [$]$1"
4550 ])dnl
4551 dnl ---------------------------------------------------------------------------
4552 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
4553 dnl ------------------
4554 AC_DEFUN([CF_LIBTOOL_VERSION],[
4555 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
4556 then
4557         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
4558 else
4559         cf_cv_libtool_version=
4560 fi
4561 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
4562 ])dnl
4563 dnl ---------------------------------------------------------------------------
4564 dnl CF_LIB_PREFIX version: 14 updated: 2021/01/01 13:31:04
4565 dnl -------------
4566 dnl Compute the library-prefix for the given host system
4567 dnl $1 = variable to set
4568 define([CF_LIB_PREFIX],
4569 [
4570         case "$cf_cv_system_name" in
4571         (OS/2*|os2*)
4572                 if test "$DFT_LWR_MODEL" = libtool; then
4573                         LIB_PREFIX='lib'
4574                 else
4575                         LIB_PREFIX=''
4576                 fi
4577                 ;;
4578         (*-msvc*)
4579                 LIB_PREFIX=''
4580                 ;;
4581         (*)     LIB_PREFIX='lib'
4582                 ;;
4583         esac
4584 ifelse($1,,,[$1=$LIB_PREFIX])
4585         AC_SUBST(LIB_PREFIX)
4586 ])dnl
4587 dnl ---------------------------------------------------------------------------
4588 dnl CF_LIB_RULES version: 100 updated: 2023/06/03 15:17:30
4589 dnl ------------
4590 dnl Append definitions and rules for the given models to the subdirectory
4591 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
4592 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
4593 dnl the corresponding makefile to list the models that we'll generate.
4594 dnl
4595 dnl For shared libraries, make a list of symbolic links to construct when
4596 dnl generating each library.  The convention used for Linux is the simplest
4597 dnl one:
4598 dnl     lib<name>.so    ->
4599 dnl     lib<name>.so.<major>    ->
4600 dnl     lib<name>.so.<maj>.<minor>
4601 dnl
4602 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
4603 AC_DEFUN([CF_LIB_RULES],
4604 [AC_REQUIRE([AC_PROG_FGREP])dnl
4605 AC_REQUIRE([CF_MAKE_PHONY])dnl
4606
4607 cf_prefix=$LIB_PREFIX
4608 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
4609
4610 case "$cf_cv_shlib_version" in
4611 (cygdll|msysdll|mingw|msvcdll)
4612         TINFO_NAME=$TINFO_ARG_SUFFIX
4613         TINFO_SUFFIX=.dll
4614         ;;
4615 esac
4616
4617 if test -n "$TINFO_SUFFIX" ; then
4618         case "$TINFO_SUFFIX" in
4619         (tw*)
4620                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
4621                 TINFO_SUFFIX=`echo "$TINFO_SUFFIX" | sed 's/^tw'$EXTRA_SUFFIX'//'`
4622                 ;;
4623         (t*)
4624                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
4625                 TINFO_SUFFIX=`echo "$TINFO_SUFFIX" | sed 's/^t'$EXTRA_SUFFIX'//'`
4626                 ;;
4627         (w*)
4628                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
4629                 TINFO_SUFFIX=`echo "$TINFO_SUFFIX" | sed 's/^w'$EXTRA_SUFFIX'//'`
4630                 ;;
4631         esac
4632 fi
4633
4634 for cf_dir in $SRC_SUBDIRS
4635 do
4636         if test ! -d "$srcdir/$cf_dir" ; then
4637                 continue
4638         elif test -f "$srcdir/$cf_dir/modules" ; then
4639
4640                 SHARED_LIB=
4641                 Libs_To_Make=
4642                 cf_awk_program=
4643                 if test -n "${cf_cv_abi_default}" && test "x${cf_cv_abi_default}" != "x5"
4644                 then
4645                         cf_awk_program="$cf_awk_program\
4646 /deprecated in ABI${cf_cv_abi_default}/ { next; }\
4647 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_default}\"); }\
4648 "
4649                 fi
4650
4651                 if test "x$WILDCARD_SYMS" = xno
4652                 then
4653                         cf_awk_program="$cf_awk_program\
4654 /[[     ]]_\\*;/ { skip=1; next; }\
4655 "
4656                 fi
4657
4658                 if test "x$cf_awk_program" != "x"
4659                 then
4660                         cat >>$cf_dir/Makefile <<CF_EOF
4661
4662 # Generated by CF_LIB_RULES
4663 resulting.map: $UNALTERED_SYMS
4664         $AWK 'BEGIN { skip = 1; last=""; } \
4665 $cf_awk_program \
4666 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
4667  skip = 0; last = \[$]\[$]0; } \
4668 END { print last; }' < "$UNALTERED_SYMS" >\[$]@
4669
4670 distclean::
4671         rm -f resulting.map
4672 CF_EOF
4673                 fi
4674
4675                 for cf_item in $cf_LIST_MODELS
4676                 do
4677                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4678                         if test "$cf_dir" = "c++"
4679                         then
4680                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4681                         else
4682                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4683                         fi
4684                         test -z "$cf_libname" && cf_libname="$cf_dir"
4685                         if test "$cf_item" = shared ; then
4686                                 if test -n "${LIB_SUFFIX}"
4687                                 then
4688                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4689                                 else
4690                                         cf_shared_suffix="$cf_suffix"
4691                                 fi
4692                                 if test "$cf_cv_do_symlinks" = yes ; then
4693                                         cf_version_name=
4694
4695                                         case "$cf_cv_shlib_version" in
4696                                         (rel)
4697                                                 cf_version_name=REL_VERSION
4698                                                 ;;
4699                                         (abi)
4700                                                 cf_version_name=ABI_VERSION
4701                                                 ;;
4702                                         esac
4703
4704                                         if test -n "$cf_version_name"
4705                                         then
4706                                                 case "$cf_cv_system_name" in
4707                                                 (darwin*)
4708                                                         # "w", etc?
4709                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
4710                                                         ;;
4711                                                 (*)
4712                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
4713                                                         ;;
4714                                                 esac
4715                                         fi
4716                                         if test -n "${USE_LIB_SUFFIX}"
4717                                         then
4718                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4719                                         else
4720                                                 cf_shared_suffix="$cf_suffix"
4721                                         fi
4722                                 fi
4723                                 # cygwin needs import library, and has unique naming convention
4724                                 # use autodetected ${cf_prefix} for import lib and static lib, but
4725                                 # use 'cyg' prefix for shared lib.
4726                                 case "$cf_cv_shlib_version" in
4727                                 (cygdll)
4728                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4729                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
4730                                         ;;
4731                                 (msysdll)
4732                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4733                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
4734                                         ;;
4735                                 (mingw)
4736                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4737                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
4738                                         ;;
4739                                 (msvcdll)
4740                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4741                                         cf_add_lib="../lib/${cf_libname}${cf_cygsuf}"
4742                                         ;;
4743                                 (*)
4744                                         cf_add_lib=
4745                                         ;;
4746                                 esac
4747                                 if test -n "$cf_add_lib"
4748                                 then
4749                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4750                                         continue
4751                                 fi
4752                         fi
4753                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
4754                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4755                 done
4756
4757                 if test "$cf_dir" = ncurses ; then
4758                         cf_subsets="$LIB_SUBSETS"
4759                         cf_r_parts="$cf_subsets"
4760                         cf_liblist="$Libs_To_Make"
4761
4762                         while test -n "$cf_r_parts"
4763                         do
4764                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
4765                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
4766                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
4767                                         cf_add_lib=
4768                                         case "$cf_l_parts" in
4769                                         (*termlib*)
4770                                                 cf_add_lib=`echo "$cf_liblist" |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
4771                                                 ;;
4772                                         (*ticlib*)
4773                                                 cf_add_lib=`echo "$cf_liblist" |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
4774                                                 ;;
4775                                         (*)
4776                                                 break
4777                                                 ;;
4778                                         esac
4779                                         if test -n "$cf_add_lib"; then
4780                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
4781                                         fi
4782                                 else
4783                                         break
4784                                 fi
4785                         done
4786                 else
4787                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
4788                 fi
4789
4790                 if test "$cf_dir" = c++; then
4791                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
4792                                 cf_list=
4793                                 for cf_item in $Libs_To_Make
4794                                 do
4795                                         case "$cf_item" in
4796                                         (*.a)
4797                                                 ;;
4798                                         (*)
4799                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
4800                                                 ;;
4801                                         esac
4802                                         for cf_test in $cf_list
4803                                         do
4804                                                 if test "$cf_test" = "$cf_item"
4805                                                 then
4806                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
4807                                                         cf_item=
4808                                                         break
4809                                                 fi
4810                                         done
4811                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
4812                                 done
4813                                 Libs_To_Make="$cf_list"
4814                         fi
4815                 fi
4816
4817                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
4818                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
4819                         "$cf_dir/Makefile" >$cf_dir/Makefile.out
4820                 mv "$cf_dir/Makefile.out" "$cf_dir/Makefile"
4821
4822                 $AWK -f "$srcdir/mk-0th.awk" \
4823                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
4824                         "$srcdir/$cf_dir/modules" >>$cf_dir/Makefile
4825
4826                 for cf_subset in $cf_subsets
4827                 do
4828                         cf_subdirs=
4829                         for cf_item in $cf_LIST_MODELS
4830                         do
4831
4832                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
4833                         CF_UPPER(cf_ITEM,$cf_item)
4834
4835                         CXX_MODEL=$cf_ITEM
4836                         if test "$CXX_MODEL" = SHARED; then
4837                                 case "$cf_cv_shlib_version" in
4838                                 (cygdll|msysdll|mingw|msvcdll)
4839                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
4840                                         with_shared_cxx=yes
4841                                         ;;
4842                                 (*)
4843                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
4844                                         ;;
4845                                 esac
4846                         fi
4847
4848                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4849                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
4850
4851                         # Test for case where we build libtinfo with a different name.
4852                         cf_libname=$cf_dir
4853                         if test "$cf_dir" = ncurses ; then
4854                                 case "$cf_subset" in
4855                                 (*base*)
4856                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
4857                                         ;;
4858                                 (*termlib*)
4859                                         cf_libname=$TINFO_LIB_SUFFIX
4860                                         ;;
4861                                 (ticlib*)
4862                                         cf_libname=$TICS_LIB_SUFFIX
4863                                         ;;
4864                                 esac
4865                         elif test "$cf_dir" = c++ ; then
4866                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4867                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4868                         else
4869                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4870                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4871                         fi
4872                         if test -n "${USE_ARG_SUFFIX}" ; then
4873                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
4874                                 cf_suffix=`echo "$cf_suffix" |sed -e "s%^${USE_LIB_SUFFIX}%%"`
4875                         fi
4876
4877                         # These dependencies really are for development, not
4878                         # builds, but they are useful in porting, too.
4879                         cf_depend="../include/ncurses_cfg.h"
4880                         if test "$srcdir" = "."; then
4881                                 cf_reldir="."
4882                         else
4883                                 cf_reldir="\${srcdir}"
4884                         fi
4885
4886                         if test -f "$srcdir/$cf_dir/$cf_dir.priv.h" ; then
4887                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
4888                         elif test -f "$srcdir/$cf_dir/curses.priv.h" ; then
4889                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
4890                         fi
4891
4892                         cf_dir_suffix=
4893                         old_cf_suffix="$cf_suffix"
4894                         if test "$cf_cv_shlib_version_infix" = yes ; then
4895                         if test -n "$USE_LIB_SUFFIX" ; then
4896                                 case "$USE_LIB_SUFFIX" in
4897                                 (tw*)
4898                                         cf_libname=`echo "$cf_libname" | sed 's/tw'$EXTRA_SUFFIX'$//'`
4899                                         cf_suffix=`echo "$cf_suffix" | sed 's/^tw'$EXTRA_SUFFIX'//'`
4900                                         cf_dir_suffix=tw$EXTRA_SUFFIX
4901                                         ;;
4902                                 (t*)
4903                                         cf_libname=`echo "$cf_libname" | sed 's/t'$EXTRA_SUFFIX'$//'`
4904                                         cf_suffix=`echo "$cf_suffix" | sed 's/^t'$EXTRA_SUFFIX'//'`
4905                                         cf_dir_suffix=t$EXTRA_SUFFIX
4906                                         ;;
4907                                 (w*)
4908                                         cf_libname=`echo "$cf_libname" | sed 's/w'$EXTRA_SUFFIX'$//'`
4909                                         cf_suffix=`echo "$cf_suffix" | sed 's/^w'$EXTRA_SUFFIX'//'`
4910                                         cf_dir_suffix=w$EXTRA_SUFFIX
4911                                         ;;
4912                                 (*)
4913                                         cf_libname=`echo "$cf_libname" | sed 's/'$EXTRA_SUFFIX'$//'`
4914                                         cf_suffix=`echo "$cf_suffix" | sed 's/^'$EXTRA_SUFFIX'//'`
4915                                         cf_dir_suffix=$EXTRA_SUFFIX
4916                                         ;;
4917                                 esac
4918                         fi
4919                         fi
4920
4921                         $AWK -f "$srcdir/mk-1st.awk" \
4922                                 name=${cf_libname}${cf_dir_suffix} \
4923                                 traces=$LIB_TRACING \
4924                                 MODEL=$cf_ITEM \
4925                                 CXX_MODEL=$CXX_MODEL \
4926                                 LIB_SUFFIX=$LIB_SUFFIX \
4927                                 USE_LIB_SUFFIX=$USE_LIB_SUFFIX \
4928                                 make_phony="${cf_cv_make_PHONY:-no}" \
4929                                 model=$cf_subdir \
4930                                 prefix=$cf_prefix \
4931                                 suffix=$cf_suffix \
4932                                 subset=$cf_subset \
4933                                 driver=$cf_cv_term_driver \
4934                                 SymLink="$LN_S" \
4935                                 TermlibRoot=$TINFO_NAME \
4936                                 TermlibSuffix=$TINFO_SUFFIX \
4937                                 ShlibVer=$cf_cv_shlib_version \
4938                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
4939                                 ReLink=${cf_cv_do_relink:-no} \
4940                                 ReRanlib=${cf_cv_do_reranlib:-yes} \
4941                                 DoLinks=$cf_cv_do_symlinks \
4942                                 rmSoLocs=$cf_cv_rm_so_locs \
4943                                 ldconfig="$LDCONFIG" \
4944                                 overwrite=$WITH_OVERWRITE \
4945                                 depend="$cf_depend" \
4946                                 host="$host" \
4947                                 libtool_version="$LIBTOOL_VERSION" \
4948                                 "$srcdir/$cf_dir/modules" >>$cf_dir/Makefile
4949
4950                         cf_suffix="$old_cf_suffix"
4951
4952                         for cf_subdir2 in $cf_subdirs lib
4953                         do
4954                                 test "$cf_subdir" = "$cf_subdir2" && break
4955                         done
4956                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
4957                         $AWK -f "$srcdir/mk-2nd.awk" \
4958                                 name=$cf_dir \
4959                                 traces=$LIB_TRACING \
4960                                 MODEL=$cf_ITEM \
4961                                 model=$cf_subdir \
4962                                 subset=$cf_subset \
4963                                 srcdir=$srcdir \
4964                                 echo=$WITH_ECHO \
4965                                 crenames=$cf_cv_prog_CC_c_o \
4966                                 cxxrenames=$cf_cv_prog_CXX_c_o \
4967                                 "$srcdir/$cf_dir/modules" >>$cf_dir/Makefile
4968                         cf_subdirs="$cf_subdirs $cf_subdir"
4969                         done
4970                 done
4971         fi
4972
4973         echo '  ( cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@ )' >>Makefile
4974 done
4975
4976 echo >> Makefile
4977 echo '# generated by CF_LIB_RULES' >> Makefile
4978
4979 if test "x$cf_cv_make_PHONY" = xyes ; then
4980         cat >> Makefile <<-CF_EOF
4981
4982         .PHONY :        libs
4983         .PHONY :        lintlib
4984         .PHONY :        install.includes
4985         .PHONY :        uninstall.includes
4986         .PHONY :        install.libs
4987         .PHONY :        uninstall.libs
4988 CF_EOF
4989 fi
4990
4991 for cf_dir in $SRC_SUBDIRS
4992 do
4993         if test ! -d "$srcdir/$cf_dir" ; then
4994                 continue
4995         fi
4996
4997         if test -f "$cf_dir/Makefile" ; then
4998                 case "$cf_dir" in
4999                 (Ada95)
5000                         echo 'libs \' >> Makefile
5001                         echo 'install.libs \' >> Makefile
5002                         echo 'uninstall.libs ::' >> Makefile
5003                         echo '  ( cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@ )' >> Makefile
5004                         ;;
5005                 esac
5006         fi
5007
5008         if test -f "$srcdir/$cf_dir/modules" ; then
5009
5010                 if test "x$cf_cv_make_PHONY" = xyes ; then
5011                         cat >> Makefile <<-CF_EOF
5012
5013                         .PHONY :        install.$cf_dir
5014                         .PHONY :        uninstall.$cf_dir
5015 CF_EOF
5016                 fi
5017
5018                 echo >> Makefile
5019                 if test -f "$srcdir/$cf_dir/headers" ; then
5020 cat >> Makefile <<CF_EOF
5021 install.includes \\
5022 uninstall.includes \\
5023 CF_EOF
5024                 fi
5025
5026 cat >> Makefile <<CF_EOF
5027 lint \\
5028 libs \\
5029 lintlib \\
5030 install.libs \\
5031 uninstall.libs \\
5032 install.$cf_dir \\
5033 uninstall.$cf_dir ::
5034         ( cd "$cf_dir" && \${MAKE} \${TOP_MFLAGS} \[$]@ )
5035 CF_EOF
5036         elif test -f "$srcdir/$cf_dir/headers" ; then
5037 cat >> Makefile <<CF_EOF
5038
5039 libs \\
5040 install.libs \\
5041 uninstall.libs \\
5042 install.includes \\
5043 uninstall.includes ::
5044         ( cd "$cf_dir" && \${MAKE} \${TOP_MFLAGS} \[$]@ )
5045 CF_EOF
5046 fi
5047 done
5048
5049 if test "x$cf_cv_make_PHONY" = xyes ; then
5050         cat >> Makefile <<-CF_EOF
5051
5052         .PHONY :        install.data
5053         .PHONY :        uninstall.data
5054 CF_EOF
5055 fi
5056
5057 if test "x$cf_with_db_install" = xyes; then
5058 cat >> Makefile <<CF_EOF
5059
5060 install.libs uninstall.libs \\
5061 install.data uninstall.data ::
5062 $MAKE_TERMINFO  ( cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@ )
5063 CF_EOF
5064 else
5065 cat >> Makefile <<CF_EOF
5066
5067 install.libs uninstall.libs ::
5068         ( cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@ )
5069 CF_EOF
5070 fi
5071
5072 if test "x$cf_with_manpages" = xyes; then
5073
5074 if test "x$cf_cv_make_PHONY" = xyes ; then
5075         cat >> Makefile <<-CF_EOF
5076
5077         .PHONY :        install.man
5078         .PHONY :        uninstall.man
5079 CF_EOF
5080 fi
5081
5082 cat >> Makefile <<CF_EOF
5083
5084 install.man \\
5085 uninstall.man ::
5086         ( cd man && \${MAKE} \${TOP_MFLAGS} \[$]@ )
5087 CF_EOF
5088 fi
5089
5090 cat >> Makefile <<CF_EOF
5091
5092 distclean ::
5093         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
5094         rm -f headers.sh headers.sed mk_shared_lib.sh
5095         rm -f edit_man.* man_alias.* *.tmp
5096         rm -rf \${DIRS_TO_MAKE}
5097 CF_EOF
5098
5099 dnl If we're installing into a subdirectory of /usr/include, etc., we should
5100 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
5101 dnl anything, and will make it more standardized.  It's awkward to decide this
5102 dnl at configuration because of quoting, so we'll simply make all headers
5103 dnl installed via a script that can do the right thing.
5104
5105 rm -f headers.sed headers.sh
5106
5107 dnl ( generating this script makes the makefiles a little tidier :-)
5108 echo creating headers.sh
5109 cat >headers.sh <<CF_EOF
5110 #! $SHELL
5111 # This shell script is generated by the 'configure' script.  It is invoked in a
5112 # subdirectory of the build tree.  It generates a sed-script in the parent
5113 # directory that is used to adjust includes for header files that reside in a
5114 # subdirectory of /usr/include, etc.
5115 PRG=""
5116 while test \[$]# != 3
5117 do
5118 PRG="\$PRG \[$]1"; shift
5119 done
5120 DST=\[$]1
5121 REF=\[$]2
5122 SRC=\[$]3
5123 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
5124 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
5125 echo installing \$SRC in \$DST
5126 CF_EOF
5127
5128 if test "$WITH_CURSES_H" = yes; then
5129         cat >>headers.sh <<CF_EOF
5130 case \$DST in
5131 (/*/include/*)
5132         END=\`basename \$DST\`
5133         for i in \`cat \$REF/../*/headers |${FGREP-fgrep} -v "#"\`
5134         do
5135                 NAME=\`basename \$i\`
5136                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
5137         done
5138         ;;
5139 (*)
5140         echo "" >> \$TMPSED
5141         ;;
5142 esac
5143 CF_EOF
5144
5145 else
5146         cat >>headers.sh <<CF_EOF
5147 case \$DST in
5148 (/*/include/*)
5149         END=\`basename \$DST\`
5150         for i in \`cat \$REF/../*/headers |${FGREP-fgrep} -v "#"\`
5151         do
5152                 NAME=\`basename \$i\`
5153                 if test "\$NAME" = "curses.h"
5154                 then
5155                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
5156                         NAME=ncurses.h
5157                 fi
5158                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
5159         done
5160         ;;
5161 (*)
5162         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
5163         ;;
5164 esac
5165 CF_EOF
5166 fi
5167 cat >>headers.sh <<CF_EOF
5168 rm -f \$TMPSRC
5169 sed -f \$TMPSED \$SRC > \$TMPSRC
5170 NAME=\`basename \$SRC\`
5171 CF_EOF
5172 if test "$WITH_CURSES_H" != yes; then
5173         cat >>headers.sh <<CF_EOF
5174 test "\$NAME" = "curses.h" && NAME=ncurses.h
5175 CF_EOF
5176 fi
5177 cat >>headers.sh <<CF_EOF
5178 # Just in case someone gzip'd manpages, remove the conflicting copy.
5179 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
5180
5181 eval \$PRG \$TMPSRC \$DST/\$NAME
5182 rm -f \$TMPSRC \$TMPSED
5183 CF_EOF
5184
5185 chmod 0755 headers.sh
5186
5187 for cf_dir in $SRC_SUBDIRS
5188 do
5189         if test ! -d "$srcdir/$cf_dir" ; then
5190                 continue
5191         fi
5192
5193         if test -f "$srcdir/$cf_dir/headers" ; then
5194                 $AWK -f "$srcdir/mk-hdr.awk" \
5195                         subset="$LIB_SUBSETS" \
5196                         compat="$WITH_CURSES_H" \
5197                         "$srcdir/$cf_dir/headers" >>$cf_dir/Makefile
5198         fi
5199
5200         if test -f "$srcdir/$cf_dir/modules" ; then
5201                 if test "$cf_dir" != "c++" ; then
5202                         if test "x$cf_cv_make_PHONY" = xyes ; then
5203                                 cat >> $cf_dir/Makefile <<-CF_EOF
5204
5205                                 .PHONY :        depend
5206 CF_EOF
5207                         fi
5208
5209                         cat >>$cf_dir/Makefile <<"CF_EOF"
5210 depend : ${AUTO_SRC}
5211         makedepend -- ${CPPFLAGS} -- ${C_SRC}
5212
5213 # DO NOT DELETE THIS LINE -- make depend depends on it.
5214 CF_EOF
5215                 fi
5216         fi
5217 done
5218 AC_SUBST(Libs_To_Make)
5219 ])dnl
5220 dnl ---------------------------------------------------------------------------
5221 dnl CF_LIB_SONAME version: 9 updated: 2021/01/04 18:48:01
5222 dnl -------------
5223 dnl Find the and soname for the given shared library.  Set the cache variable
5224 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
5225 dnl variable to "unknown".
5226 dnl
5227 dnl $1 = headers
5228 dnl $2 = code
5229 dnl $3 = library name
5230 AC_DEFUN([CF_LIB_SONAME],
5231 [AC_REQUIRE([AC_PROG_FGREP])dnl
5232
5233 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
5234
5235 cf_cv_$3_soname=unknown
5236 if test "$cross_compiling" != yes ; then
5237 cat >conftest.$ac_ext <<CF_EOF
5238 $1
5239 int main(void)
5240 {
5241 $2
5242         ${cf_cv_main_return:-return}(0);
5243 }
5244 CF_EOF
5245 cf_save_LIBS="$LIBS"
5246         CF_ADD_LIB($3)
5247         if AC_TRY_EVAL(ac_compile) ; then
5248                 if AC_TRY_EVAL(ac_link) ; then
5249                         cf_cv_$3_soname="`ldd \"conftest$ac_exeext\" 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | ${FGREP-fgrep} lib$3.`"
5250                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
5251                 fi
5252         fi
5253 rm -rf ./conftest*
5254 LIBS="$cf_save_LIBS"
5255 fi
5256 ])
5257 ])
5258 dnl ---------------------------------------------------------------------------
5259 dnl CF_LIB_SUFFIX version: 28 updated: 2021/01/01 16:53:59
5260 dnl -------------
5261 dnl Compute the library file-suffix from the given model name
5262 dnl $1 = model name
5263 dnl $2 = variable to set (the nominal library suffix)
5264 dnl $3 = dependency variable to set (actual filename)
5265 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
5266 AC_DEFUN([CF_LIB_SUFFIX],
5267 [
5268         case X$1 in
5269         (Xlibtool)
5270                 $2='.la'
5271                 $3=[$]$2
5272                 ;;
5273         (Xdebug)
5274                 case "$cf_cv_system_name" in
5275                 (*-msvc*)
5276                         $2='_g.lib'
5277                         ;;
5278                 (*)
5279                         $2='_g.a'
5280                         ;;
5281                 esac
5282                 $3=[$]$2
5283                 ;;
5284         (Xprofile)
5285                 case "$cf_cv_system_name" in
5286                 (*-msvc*)
5287                         $2='_p.lib'
5288                         ;;
5289                 (*)
5290                         $2='_p.a'
5291                         ;;
5292                 esac
5293                 $3=[$]$2
5294                 ;;
5295         (Xshared)
5296                 case "$cf_cv_system_name" in
5297                 (aix[[5-7]]*)
5298                         $2='.so'
5299                         $3=[$]$2
5300                         ;;
5301                 (*-msvc*)
5302                         $2='.dll'
5303                         $3='.dll.lib'
5304                         ;;
5305                 (cygwin*|msys*|mingw*)
5306                         $2='.dll'
5307                         $3='.dll.a'
5308                         ;;
5309                 (darwin*)
5310                         $2='.dylib'
5311                         $3=[$]$2
5312                         ;;
5313                 (hpux*)
5314                         case "$target" in
5315                         (ia64*)
5316                                 $2='.so'
5317                                 $3=[$]$2
5318                                 ;;
5319                         (*)
5320                                 $2='.sl'
5321                                 $3=[$]$2
5322                                 ;;
5323                         esac
5324                         ;;
5325                 (*)
5326                         $2='.so'
5327                         $3=[$]$2
5328                         ;;
5329                 esac
5330                 ;;
5331         (*)
5332                 case "$target" in
5333                 (*-msvc*)
5334                         $2='.lib'
5335                         ;;
5336                 (*)
5337                         $2='.a'
5338                         ;;
5339                 esac
5340                 $3=[$]$2
5341                 ;;
5342         esac
5343         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
5344         then
5345                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
5346                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
5347         fi
5348 ])dnl
5349 dnl ---------------------------------------------------------------------------
5350 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
5351 dnl -----------
5352 dnl Compute the string to append to -library from the given model name
5353 dnl $1 = model name
5354 dnl $2 = variable to set
5355 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
5356 AC_DEFUN([CF_LIB_TYPE],
5357 [
5358         case $1 in
5359         (libtool) $2=''   ;;
5360         (normal)  $2=''   ;;
5361         (debug)   $2='_g' ;;
5362         (profile) $2='_p' ;;
5363         (shared)  $2=''   ;;
5364         esac
5365         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
5366 ])dnl
5367 dnl ---------------------------------------------------------------------------
5368 dnl CF_LINK_DATAONLY version: 13 updated: 2020/02/08 15:59:30
5369 dnl ----------------
5370 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
5371 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
5372 dnl have to provide wrappers for global tables to ensure they're linked
5373 dnl properly.
5374 AC_DEFUN([CF_LINK_DATAONLY],
5375 [
5376 AC_MSG_CHECKING([if data-only library module links])
5377 AC_CACHE_VAL(cf_cv_link_dataonly,[
5378         rm -f conftest.a
5379         cat >conftest.$ac_ext <<EOF
5380 #line __oline__ "configure"
5381 int     testdata[[3]] = { 123, 456, 789 };
5382 EOF
5383         if AC_TRY_EVAL(ac_compile) ; then
5384                 mv conftest.o data.o && \
5385                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
5386         fi
5387         rm -f conftest.$ac_ext data.o
5388         cat >conftest.$ac_ext <<EOF
5389 #line __oline__ "configure"
5390 int     testfunc(void)
5391 {
5392 #if defined(NeXT)
5393         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
5394 #else
5395         extern int testdata[[3]];
5396         return testdata[[0]] == 123
5397            &&  testdata[[1]] == 456
5398            &&  testdata[[2]] == 789;
5399 #endif
5400 }
5401 EOF
5402         if AC_TRY_EVAL(ac_compile); then
5403                 mv conftest.o func.o && \
5404                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
5405         fi
5406         rm -f conftest.$ac_ext func.o
5407         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
5408         cf_saveLIBS="$LIBS"
5409         LIBS="conftest.a $LIBS"
5410         AC_TRY_RUN([
5411         int main(void)
5412         {
5413                 extern int testfunc();
5414                 ${cf_cv_main_return:-return} (!testfunc());
5415         }
5416         ],
5417         [cf_cv_link_dataonly=yes],
5418         [cf_cv_link_dataonly=no],
5419         [cf_cv_link_dataonly=unknown])
5420         LIBS="$cf_saveLIBS"
5421         ])
5422 AC_MSG_RESULT($cf_cv_link_dataonly)
5423
5424 if test "$cf_cv_link_dataonly" = no ; then
5425         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
5426         BROKEN_LINKER=1
5427 fi
5428 AC_SUBST(BROKEN_LINKER)
5429
5430 ])dnl
5431 dnl ---------------------------------------------------------------------------
5432 dnl CF_LINK_FUNCS version: 12 updated: 2023/01/05 17:51:41
5433 dnl -------------
5434 dnl Most Unix systems have both link and symlink, a few don't have symlink.
5435 dnl A few non-Unix systems implement symlink, but not link.
5436 dnl A few non-systems implement neither (or have nonfunctional versions).
5437 dnl
5438 dnl This allows for a 2-second difference in modification times to allow for
5439 dnl some marginal NFS implementations.
5440 AC_DEFUN([CF_LINK_FUNCS],
5441 [
5442 AC_CHECK_HEADERS( \
5443 unistd.h \
5444 )
5445 AC_CHECK_FUNCS( \
5446         remove \
5447         unlink )
5448
5449 if test "$cross_compiling" = yes ; then
5450         AC_CHECK_FUNCS( \
5451                 link \
5452                 symlink )
5453 else
5454         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
5455                 cf_cv_link_funcs=
5456                 for cf_func in link symlink ; do
5457                         AC_TRY_RUN([
5458 $ac_includes_default
5459
5460 int main(void)
5461 {
5462         int fail = 0;
5463         char *src = "conftest.tmp";
5464         char *dst = "conftest.chk";
5465         struct stat src_sb, dst_sb;
5466         FILE *fp = fopen(src, "w");
5467         if (fp == 0) { fail = 3; } else {
5468                 fclose(fp); stat(src, &src_sb);
5469                 if ($cf_func(src, dst) < 0) {
5470                         fail = 1;
5471                 } else if (stat(dst, &dst_sb) < 0) {
5472                         fail = 2;
5473                 } else {
5474                         long diff = (dst_sb.st_mtime - src_sb.st_mtime);
5475                         if (diff < 0) diff = -diff;
5476                         if (diff > 2) fail = 3;
5477                 }
5478         }
5479 #ifdef HAVE_UNLINK
5480         unlink(dst); unlink(src);
5481 #else
5482         remove(dst); remove(src);
5483 #endif
5484         ${cf_cv_main_return:-return} (fail);
5485 }
5486                         ],[
5487                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
5488                         eval 'ac_cv_func_'$cf_func'=yes'],[
5489                         eval 'ac_cv_func_'$cf_func'=no'],[
5490                         eval 'ac_cv_func_'$cf_func'=error'])
5491                 done
5492                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
5493         ])
5494         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
5495         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
5496 fi
5497 ])dnl
5498 dnl ---------------------------------------------------------------------------
5499 dnl CF_MAKEFLAGS version: 21 updated: 2021/09/04 06:47:34
5500 dnl ------------
5501 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
5502 dnl options to lower-levels.  It is very useful for "make -n" -- if we have it.
5503 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
5504 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
5505 AC_DEFUN([CF_MAKEFLAGS],
5506 [AC_REQUIRE([AC_PROG_FGREP])dnl
5507
5508 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
5509         cf_cv_makeflags=''
5510         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
5511         do
5512                 cat >cf_makeflags.tmp <<CF_EOF
5513 SHELL = $SHELL
5514 all :
5515         @ echo '.$cf_option'
5516 CF_EOF
5517                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | ${FGREP-fgrep} -v "ing directory" | sed -e 's,[[  ]]*$,,'`
5518                 case "$cf_result" in
5519                 (.*k|.*kw)
5520                         cf_result="`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`"
5521                         case "$cf_result" in
5522                         (.*CC=*)        cf_cv_makeflags=
5523                                 ;;
5524                         (*)     cf_cv_makeflags=$cf_option
5525                                 ;;
5526                         esac
5527                         break
5528                         ;;
5529                 (.-)
5530                         ;;
5531                 (*)
5532                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
5533                         ;;
5534                 esac
5535         done
5536         rm -f cf_makeflags.tmp
5537 ])
5538
5539 AC_SUBST(cf_cv_makeflags)
5540 ])dnl
5541 dnl ---------------------------------------------------------------------------
5542 dnl CF_MAKE_PHONY version: 3 updated: 2021/01/08 16:08:21
5543 dnl -------------
5544 dnl Check if the make-program handles a ".PHONY" target, e.g,. a target which
5545 dnl acts as a placeholder.
5546 dnl
5547 dnl The ".PHONY" feature was proposed in 2011 here
5548 dnl     https://www.austingroupbugs.net/view.php?id=523
5549 dnl and is scheduled for release in P1003.1 Issue 8 (late 2022).
5550 dnl
5551 dnl This is not supported by SVr4 make (or SunOS 4, 4.3SD, etc), but works with
5552 dnl a few others (i.e., GNU make and the non-POSIX "BSD" make):
5553 dnl
5554 dnl + This is a GNU make feature (since April 1988, but in turn from binutils,
5555 dnl   date unspecified).
5556 dnl
5557 dnl + It was adopted in NetBSD make in June 1995.
5558 dnl
5559 dnl + The other BSD make programs are derived from the NetBSD make (and for
5560 dnl   that reason are not actually different "implementations").
5561 dnl
5562 dnl + Some features of NetBSD make were actually adapted from pmake, which
5563 dnl   began as a modified GNU make starting in 1993.
5564 dnl
5565 dnl + Version 3.8 of the dmake program in January 1992 also implemented this
5566 dnl   GNU make extension, but is less well known than the BSD make.
5567 AC_DEFUN([CF_MAKE_PHONY],[
5568 AC_CACHE_CHECK(for \".PHONY\" make-support, cf_cv_make_PHONY,[
5569         rm -rf conftest*
5570         (
5571                 mkdir conftest || exit 1
5572                 cd conftest
5573                 cat >makefile <<'CF_EOF'
5574 .PHONY: always
5575 DATA=0
5576 always: always.out
5577         @echo "** making [$]@ [$](DATA)"
5578 once: once.out
5579         @echo "** making [$]@ [$](DATA)"
5580 always.out:
5581         @echo "** making [$]@ [$](DATA)"
5582         echo [$](DATA) > [$]@
5583 once.out:
5584         @echo "** making [$]@ [$](DATA)"
5585         echo [$](DATA) > [$]@
5586 CF_EOF
5587                 for cf_data in 1 2 3
5588                 do
5589                         ${MAKE:-make} always DATA=$cf_data
5590                         ${MAKE:-make} once   DATA=$cf_data
5591                         ${MAKE:-make} -t always once
5592                         if test -f always ; then
5593                                 echo "no (case 1)" > ../conftest.tmp
5594                         elif test ! -f always.out ; then
5595                                 echo "no (case 2)" > ../conftest.tmp
5596                         elif test ! -f once.out ; then
5597                                 echo "no (case 3)" > ../conftest.tmp
5598                         elif ! cmp -s always.out once.out ; then
5599                                 echo "no (case 4)" > ../conftest.tmp
5600                                 diff always.out once.out
5601                         else
5602                                 cf_check="`cat always.out`"
5603                                 if test "x$cf_check" != "x$cf_data" ; then
5604                                         echo "no (case 5)" > ../conftest.tmp
5605                                 else
5606                                         echo yes > ../conftest.tmp
5607                                         rm -f ./*.out
5608                                         continue
5609                                 fi
5610                         fi
5611                         break
5612                 done
5613         ) >&AC_FD_CC 2>&1
5614         cf_cv_make_PHONY="`cat conftest.tmp`"
5615         rm -rf conftest*
5616 ])
5617 MAKE_NO_PHONY="#"
5618 MAKE_PHONY="#"
5619 test "x$cf_cv_make_PHONY" = xyes && MAKE_PHONY=
5620 test "x$cf_cv_make_PHONY" != xyes && MAKE_NO_PHONY=
5621 AC_SUBST(MAKE_NO_PHONY)
5622 AC_SUBST(MAKE_PHONY)
5623 ])dnl
5624 dnl ---------------------------------------------------------------------------
5625 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
5626 dnl ------------
5627 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
5628 dnl a monocase filesystem.
5629 AC_DEFUN([CF_MAKE_TAGS],[
5630 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
5631
5632 AC_CHECK_PROGS(CTAGS, exctags ctags)
5633 AC_CHECK_PROGS(ETAGS, exetags etags)
5634
5635 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
5636
5637 if test "$cf_cv_mixedcase" = yes ; then
5638         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
5639 else
5640         MAKE_UPPER_TAGS=no
5641 fi
5642
5643 if test "$MAKE_UPPER_TAGS" = yes ; then
5644         MAKE_UPPER_TAGS=
5645 else
5646         MAKE_UPPER_TAGS="#"
5647 fi
5648
5649 if test "$MAKE_LOWER_TAGS" = yes ; then
5650         MAKE_LOWER_TAGS=
5651 else
5652         MAKE_LOWER_TAGS="#"
5653 fi
5654
5655 AC_SUBST(CTAGS)
5656 AC_SUBST(ETAGS)
5657
5658 AC_SUBST(MAKE_UPPER_TAGS)
5659 AC_SUBST(MAKE_LOWER_TAGS)
5660 ])dnl
5661 dnl ---------------------------------------------------------------------------
5662 dnl CF_MANPAGE_FORMAT version: 18 updated: 2023/05/19 18:35:02
5663 dnl -----------------
5664 dnl Option to allow user to override automatic configuration of manpage format.
5665 dnl There are several special cases:
5666 dnl
5667 dnl     compress - man checks for, can display compressed files
5668 dnl     bzip2 - man checks for, can display bzip2'd files
5669 dnl     gzip - man checks for, can display gzip'd files
5670 dnl     xz - man checks for, can display xz'd files
5671 dnl
5672 dnl     BSDI - files in the cat-directories are suffixed ".0"
5673 dnl     formatted - installer should format (put files in cat-directory)
5674 dnl     catonly - installer should only format, e.g., for a turnkey system.
5675 dnl
5676 dnl There are other configurations which this macro does not test, e.g., HPUX's
5677 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
5678 dnl convention would not match our use).
5679 AC_DEFUN([CF_MANPAGE_FORMAT],
5680 [
5681 AC_REQUIRE([CF_PATHSEP])
5682 AC_MSG_CHECKING(format of man-pages)
5683
5684 AC_ARG_WITH(manpage-format,
5685         [  --with-manpage-format   specify manpage-format: gzip/compress/bzip2/xz,
5686                           BSDI/normal and optionally formatted/catonly,
5687                           e.g., gzip,formatted],
5688         [MANPAGE_FORMAT=$withval],
5689         [MANPAGE_FORMAT=unknown])
5690
5691 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
5692 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
5693
5694 cf_unknown=
5695
5696 case "$MANPAGE_FORMAT" in
5697 (unknown)
5698         if test -z "$MANPATH" ; then
5699                 MANPATH="/usr/man:/usr/share/man"
5700         fi
5701
5702         # look for the 'date' man-page (it is most likely to be installed!)
5703         MANPAGE_FORMAT=
5704         cf_preform="no"
5705         cf_catonly="yes"
5706         cf_example="date"
5707
5708         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
5709         for cf_dir in $MANPATH; do
5710                 test -z "$cf_dir" && cf_dir=/usr/man
5711                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
5712                 do
5713                         cf_test=`echo "$cf_name" | sed -e 's/*//'`
5714                         if test "x$cf_test" = "x$cf_name" ; then
5715
5716                                 case "$cf_name" in
5717                                 (*.bz2) MANPAGE_FORMAT="$MANPAGE_FORMAT bzip2";;
5718                                 (*.xz)  MANPAGE_FORMAT="$MANPAGE_FORMAT xz";;
5719                                 (*.gz)  MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
5720                                 (*.Z)   MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
5721                                 (*.0)   MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
5722                                 (*)     MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
5723                                 esac
5724
5725                                 case "$cf_name" in
5726                                 ($cf_dir/man*)
5727                                         cf_catonly=no
5728                                         ;;
5729                                 ($cf_dir/cat*)
5730                                         cf_preform=yes
5731                                         ;;
5732                                 esac
5733                                 break
5734                         fi
5735
5736                         # if we found a match in either man* or cat*, stop looking
5737                         if test -n "$MANPAGE_FORMAT" ; then
5738                                 cf_found=no
5739                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
5740                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
5741                                 case "$cf_name" in
5742                                 ($cf_dir/cat*)
5743                                         cf_found=yes
5744                                         ;;
5745                                 esac
5746                                 test "$cf_found" = yes && break
5747                         fi
5748                 done
5749                 # only check the first directory in $MANPATH where we find manpages
5750                 if test -n "$MANPAGE_FORMAT" ; then
5751                         break
5752                 fi
5753         done
5754         # if we did not find the example, just assume it is normal
5755         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
5756         IFS="$ac_save_ifs"
5757         ;;
5758 (*)
5759         for cf_option in $MANPAGE_FORMAT; do
5760         case "$cf_option" in
5761         (xz|bzip2|gzip|compress|BSDI|normal|formatted|catonly)
5762                 ;;
5763         (*)
5764                 cf_unknown="$cf_unknown $cf_option"
5765                 ;;
5766         esac
5767         done
5768         ;;
5769 esac
5770
5771 AC_MSG_RESULT($MANPAGE_FORMAT)
5772 if test -n "$cf_unknown" ; then
5773         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
5774 fi
5775
5776 cf_manpage_format=no
5777 cf_manpage_inboth=no
5778 cf_manpage_so_strip=
5779 cf_manpage_compress=
5780
5781 for cf_item in $MANPAGE_FORMAT
5782 do
5783 case "$cf_item" in
5784 (catonly)
5785         cf_manpage_format=yes
5786         cf_manpage_inboth=no
5787         ;;
5788 (formatted)
5789         cf_manpage_format=yes
5790         cf_manpage_inboth=yes
5791         ;;
5792 (compress)
5793         cf_manpage_so_strip="Z"
5794         cf_manpage_compress=compress
5795         ;;
5796 (gzip)
5797         cf_manpage_so_strip="gz"
5798         cf_manpage_compress=gzip
5799         ;;
5800 (bzip2)
5801         cf_manpage_so_strip="bz2"
5802         cf_manpage_compress=bzip2
5803         ;;
5804 (xz)
5805         cf_manpage_so_strip="xz"
5806         cf_manpage_compress=xz
5807         ;;
5808 esac
5809 done
5810
5811 AC_SUBST(cf_manpage_format)
5812 AC_SUBST(cf_manpage_inboth)
5813 AC_SUBST(cf_manpage_so_strip)
5814 AC_SUBST(cf_manpage_compress)
5815
5816 ])dnl
5817 dnl ---------------------------------------------------------------------------
5818 dnl CF_MANPAGE_RENAMES version: 17 updated: 2022/10/23 07:46:29
5819 dnl ------------------
5820 dnl The Debian people have their own naming convention for manpages.  This
5821 dnl option lets us override the name of the file containing renaming, or
5822 dnl disable it altogether.
5823 AC_DEFUN([CF_MANPAGE_RENAMES],
5824 [
5825 AC_MSG_CHECKING(for manpage renaming)
5826
5827 AC_ARG_WITH(manpage-renames,
5828         [  --with-manpage-renames  specify manpage-renaming],
5829         [MANPAGE_RENAMES=$withval],
5830         [MANPAGE_RENAMES=yes])
5831
5832 case ".$MANPAGE_RENAMES" in
5833 (.no)
5834         ;;
5835 (.|.yes)
5836         # Debian 'man' program?
5837         if test -f /etc/debian_version ; then
5838                 MANPAGE_RENAMES=man/man_db.renames
5839         else
5840                 MANPAGE_RENAMES=no
5841         fi
5842         ;;
5843 esac
5844
5845 if test "$MANPAGE_RENAMES" = man/man_db.renames ; then
5846         MANPAGE_RENAMES=`pwd`/$MANPAGE_RENAMES
5847 elif test "$MANPAGE_RENAMES" = no ; then
5848         :
5849 elif test ! -f "$MANPAGE_RENAMES" ; then
5850         AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
5851 fi
5852
5853 AC_MSG_RESULT($MANPAGE_RENAMES)
5854 AC_SUBST(MANPAGE_RENAMES)
5855 ])dnl
5856 dnl ---------------------------------------------------------------------------
5857 dnl CF_MANPAGE_SYMLINKS version: 7 updated: 2023/01/21 16:37:17
5858 dnl -------------------
5859 dnl Some people expect each tool to make all aliases for manpages in the
5860 dnl man-directory.  This accommodates the older, less-capable implementations
5861 dnl of 'man', and is optional.
5862 AC_DEFUN([CF_MANPAGE_SYMLINKS],
5863 [
5864 AC_MSG_CHECKING(if manpage aliases will be installed)
5865
5866 AC_ARG_WITH(manpage-aliases,
5867         [  --with-manpage-aliases  specify manpage-aliases using .so],
5868         [MANPAGE_ALIASES=$withval],
5869         [MANPAGE_ALIASES=yes])
5870
5871 AC_MSG_RESULT($MANPAGE_ALIASES)
5872
5873 case "x$LN_S" in
5874 (xln*)
5875         cf_use_symlinks=yes
5876         ;;
5877 (*)
5878         cf_use_symlinks=no
5879         ;;
5880 esac
5881
5882 MANPAGE_SYMLINKS=no
5883 if test "$MANPAGE_ALIASES" = yes ; then
5884 AC_MSG_CHECKING(if manpage symlinks should be used)
5885
5886 AC_ARG_WITH(manpage-symlinks,
5887         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
5888         [MANPAGE_SYMLINKS=$withval],
5889         [MANPAGE_SYMLINKS=$cf_use_symlinks])
5890
5891 if test "$cf_use_symlinks" = no; then
5892 if test "$MANPAGE_SYMLINKS" = yes ; then
5893         AC_MSG_WARN(cannot make symlinks, will use .so files)
5894         MANPAGE_SYMLINKS=no
5895 fi
5896 fi
5897
5898 AC_MSG_RESULT($MANPAGE_SYMLINKS)
5899 fi
5900
5901 ])dnl
5902 dnl ---------------------------------------------------------------------------
5903 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
5904 dnl --------------
5905 dnl This option causes manpages to be run through tbl(1) to generate tables
5906 dnl correctly.
5907 AC_DEFUN([CF_MANPAGE_TBL],
5908 [
5909 AC_MSG_CHECKING(for manpage tbl)
5910
5911 AC_ARG_WITH(manpage-tbl,
5912         [  --with-manpage-tbl      specify manpage processing with tbl],
5913         [MANPAGE_TBL=$withval],
5914         [MANPAGE_TBL=no])
5915
5916 AC_MSG_RESULT($MANPAGE_TBL)
5917 ])dnl
5918 dnl ---------------------------------------------------------------------------
5919 dnl CF_MAN_PAGES version: 57 updated: 2023/05/13 19:14:15
5920 dnl ------------
5921 dnl Try to determine if the man-pages on the system are compressed, and if
5922 dnl so, what format is used.  Use this information to construct a script that
5923 dnl will install man-pages.
5924 AC_DEFUN([CF_MAN_PAGES],
5925 [
5926 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
5927 CF_MANPAGE_FORMAT
5928 CF_MANPAGE_RENAMES
5929 CF_MANPAGE_SYMLINKS
5930 CF_MANPAGE_TBL
5931
5932 if test "$prefix" = "NONE" ; then
5933         cf_prefix="$ac_default_prefix"
5934 else
5935         cf_prefix="$prefix"
5936 fi
5937
5938 test ! -d man && mkdir man
5939
5940 cf_edit_man=./edit_man.sh
5941 cf_man_alias=`pwd`/man_alias.sed
5942
5943 cat >$cf_edit_man <<CF_EOF
5944 #! $SHELL
5945 # this script is generated by the configure-script CF_MAN_PAGES macro.
5946
5947 prefix="$cf_prefix"
5948 datarootdir="$datarootdir"
5949 datadir="$datadir"
5950
5951 NCURSES_MAJOR="$NCURSES_MAJOR"
5952 NCURSES_MINOR="$NCURSES_MINOR"
5953 NCURSES_PATCH="$NCURSES_PATCH"
5954
5955 NCURSES_OSPEED="$NCURSES_OSPEED"
5956 TERMINFO="$TERMINFO"
5957
5958 INSTALL="$INSTALL"
5959 INSTALL_DATA="$INSTALL_DATA"
5960
5961 transform="$program_transform_name"
5962
5963 TMP=\${TMPDIR:=/tmp}/man\$\$
5964 trap "rm -f \$TMP; exit 1" 1 2 3 15
5965 trap "rm -f \$TMP" 0
5966
5967 form=\[$]1
5968 shift || exit 1
5969
5970 verb=\[$]1
5971 shift || exit 1
5972
5973 mandir=\[$]1
5974 shift || exit 1
5975
5976 srcdir=\[$]1
5977 top_srcdir=\[$]srcdir/..
5978 shift || exit 1
5979
5980 if test "\$form" = normal ; then
5981         if test "$cf_manpage_format" = yes ; then
5982         if test "$cf_manpage_inboth" = no ; then
5983                 $SHELL "\[$]0" format "\$verb" "\$mandir" "\$srcdir" "\[$]@"
5984                 exit $?
5985         fi
5986         fi
5987         cf_subdir=\$mandir/man
5988         cf_tables=$MANPAGE_TBL
5989 else
5990         cf_subdir=\$mandir/cat
5991         cf_tables=yes
5992 fi
5993
5994 # process the list of source-files
5995 for i in "\[$]@" ; do
5996 case \$i in
5997 (*.orig|*.rej) ;;
5998 (*.[[0-9]]*)
5999         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
6000         if test "\$verb" = installing ; then
6001         if test ! -d "\$cf_subdir\${section}" ; then
6002                 mkdir -p "\$cf_subdir\$section"
6003         fi
6004         fi
6005
6006         # replace variables in man page
6007         if test ! -f "$cf_man_alias" ; then
6008 cat >>$cf_man_alias <<-CF_EOF2
6009                 s,@DATADIR@,\$datadir,g
6010                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
6011                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
6012                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
6013                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
6014                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
6015                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
6016 CF_EOF
6017         ifelse($1,,,[
6018         for cf_name in $1
6019         do
6020                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6021                 cf_name=`echo "$cf_name" | sed "$program_transform_name"`
6022 cat >>$cf_edit_man <<-CF_EOF
6023                 s,@$cf_NAME@,$cf_name,g
6024 CF_EOF
6025         done
6026         ])
6027 cat >>$cf_edit_man <<CF_EOF
6028 CF_EOF2
6029                 echo "...made $cf_man_alias"
6030         fi
6031
6032         aliases=
6033         cf_source=\`basename "\$i"\`
6034         cf_full_alias=\$cf_source
6035         test ! -f "\$cf_full_alias" && cf_full_alias="\$srcdir/\$cf_full_alias"
6036         if test ! -f "\$cf_full_alias" ; then
6037                 echo ".. skipped \$cf_source"
6038                 continue
6039         fi
6040 CF_EOF
6041
6042 if test "$MANPAGE_ALIASES" != no ; then
6043 cat >>$cf_edit_man <<CF_EOF
6044         nCurses=ignore.3x
6045         cf_part_alias=\`echo \$cf_full_alias| sed -e 's,^.*/,,'\`
6046         test "$with_curses_h" = yes && nCurses=ncurses.3x
6047         aliases=\`sed -f "\$top_srcdir/man/manlinks.sed" "\$cf_full_alias" |sed -f "$cf_man_alias" | sort -u; test "\$cf_part_alias" = "\$nCurses" && echo curses\`
6048 CF_EOF
6049 fi
6050
6051 if test "$MANPAGE_RENAMES" = no ; then
6052 cat >>$cf_edit_man <<CF_EOF
6053         # perform program transformations for section 1 man pages
6054         if test \$section = 1 ; then
6055                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
6056         else
6057                 cf_target=\$cf_subdir\${section}/\$cf_source
6058         fi
6059 CF_EOF
6060 else
6061 cat >>$cf_edit_man <<CF_EOF
6062         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
6063         if test -z "\$cf_target" ; then
6064                 echo "? missing rename for \$cf_source"
6065                 cf_target="\$cf_source"
6066         fi
6067         cf_target="\$cf_subdir\${section}/\${cf_target}"
6068
6069 CF_EOF
6070 fi
6071
6072 cat >>$cf_edit_man <<CF_EOF
6073         sed     -f "$cf_man_alias" \\
6074 CF_EOF
6075
6076 if test "$MANPAGE_RENAMES" != no ; then
6077 cat >>$cf_edit_man <<CF_EOF
6078                 < "\$i" | sed -f `pwd`/edit_man.sed >\$TMP
6079 CF_EOF
6080 else
6081 cat >>$cf_edit_man <<CF_EOF
6082                 < "\$i" >\$TMP
6083 CF_EOF
6084 fi
6085
6086 cat >>$cf_edit_man <<CF_EOF
6087 if test \$cf_tables = yes ; then
6088         tbl \$TMP >\$TMP.out
6089         mv \$TMP.out \$TMP
6090 fi
6091 CF_EOF
6092
6093 if test "$with_overwrite" != yes ; then
6094 cat >>$cf_edit_man <<CF_EOF
6095         sed -e "/\\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
6096         mv \$TMP.out \$TMP
6097 CF_EOF
6098 fi
6099
6100 if test "$with_curses_h" != yes ; then
6101 cat >>$cf_edit_man <<CF_EOF
6102         sed -e "/\\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
6103         mv \$TMP.out \$TMP
6104 CF_EOF
6105 fi
6106
6107 cat >>$cf_edit_man <<CF_EOF
6108         if test "\$form" = format ; then
6109                 nroff -man \$TMP >\$TMP.out
6110                 mv \$TMP.out \$TMP
6111         fi
6112 CF_EOF
6113
6114 if test -n "$cf_manpage_compress" ; then
6115 cat >>$cf_edit_man <<CF_EOF
6116         if test "\$verb" = installing ; then
6117         if ( "$cf_manpage_compress" -f \$TMP )
6118         then
6119                 mv \$TMP.$cf_manpage_so_strip \$TMP
6120         fi
6121         fi
6122         cf_target="\$cf_target.$cf_manpage_so_strip"
6123 CF_EOF
6124 fi
6125
6126 case "$MANPAGE_FORMAT" in
6127 (*BSDI*)
6128 cat >>$cf_edit_man <<CF_EOF
6129         if test "\$form" = format ; then
6130                 # BSDI installs only .0 suffixes in the cat directories
6131                 cf_target="\`echo \$cf_target|sed -e 's/\\.[[1-9]]\\+[[a-z]]*/.0/'\`"
6132         fi
6133 CF_EOF
6134   ;;
6135 esac
6136
6137 cat >>$cf_edit_man <<CF_EOF
6138         suffix=\`basename "\$cf_target" | sed -e 's%^[[^.]]*%%'\`
6139         extra_suffix=
6140         if test -n "$EXTRA_SUFFIX" ; then
6141                 case \$cf_target in
6142                 (*${EXTRA_SUFFIX}\$suffix)
6143                         extra_suffix="$EXTRA_SUFFIX"
6144                         ;;
6145                 esac
6146         fi
6147         if test "\$verb" = installing ; then
6148                 echo "\$verb \$cf_target"
6149                 \$INSTALL_DATA \$TMP "\$cf_target"
6150                 test -d "\$cf_subdir\${section}" &&
6151                 test -n "\$aliases" && (
6152                         cd "\$cf_subdir\${section}" && (
6153                                 cf_source=\`echo "\$cf_target" |sed -e 's%^.*/\\([[^/]][[^/]]*/[[^/]][[^/]]*$\\)%\\1%'\`
6154                                 test -n "$cf_manpage_so_strip" && cf_source=\`echo "\$cf_source" |sed -e 's%\\.$cf_manpage_so_strip\$%%'\`
6155                                 cf_target=\`basename "\$cf_target"\`
6156                                 for cf_alias in \$aliases
6157                                 do
6158                                         if test "\$section" = 1 ; then
6159                                                 cf_alias=\`echo "\$cf_alias" |sed "\${transform}"\`
6160                                         fi
6161                                         cf_alias="\${cf_alias}\${extra_suffix}"
6162
6163                                         if test "$MANPAGE_SYMLINKS" = yes ; then
6164                                                 if test -f "\$cf_alias\${suffix}" ; then
6165                                                         if ( cmp -s "\$cf_target" "\$cf_alias\${suffix}" )
6166                                                         then
6167                                                                 continue
6168                                                         fi
6169                                                 fi
6170                                                 echo ".. \$verb alias \$cf_alias\${suffix}"
6171 CF_EOF
6172 case "x$LN_S" in
6173 (*-f)
6174 cat >>$cf_edit_man <<CF_EOF
6175                                                 $LN_S "\$cf_target" "\$cf_alias\${suffix}"
6176 CF_EOF
6177         ;;
6178 (*)
6179 cat >>$cf_edit_man <<CF_EOF
6180                                                 rm -f "\$cf_alias\${suffix}"
6181                                                 $LN_S "\$cf_target" "\$cf_alias\${suffix}"
6182 CF_EOF
6183         ;;
6184 esac
6185 cat >>$cf_edit_man <<CF_EOF
6186                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
6187                                                 echo ".so \$cf_source" >\$TMP
6188 CF_EOF
6189 if test -n "$cf_manpage_compress" ; then
6190 cat >>$cf_edit_man <<CF_EOF
6191                                                 if test -n "$cf_manpage_so_strip" ; then
6192                                                         "$cf_manpage_compress" -f \$TMP
6193                                                         mv \$TMP.$cf_manpage_so_strip \$TMP
6194                                                 fi
6195 CF_EOF
6196 fi
6197 cat >>$cf_edit_man <<CF_EOF
6198                                                 echo ".. \$verb alias \$cf_alias\${suffix}"
6199                                                 rm -f "\$cf_alias\${suffix}"
6200                                                 \$INSTALL_DATA \$TMP "\$cf_alias\${suffix}"
6201                                         fi
6202                                 done
6203                         )
6204                 )
6205         elif test "\$verb" = removing ; then
6206                 test -f "\$cf_target" && (
6207                         echo "\$verb \$cf_target"
6208                         rm -f "\$cf_target"
6209                 )
6210                 test -d "\$cf_subdir\${section}" &&
6211                 test -n "\$aliases" && (
6212                         cd "\$cf_subdir\${section}" && (
6213                                 for cf_alias in \$aliases
6214                                 do
6215                                         if test "\$section" = 1 ; then
6216                                                 cf_alias=\`echo "\$cf_alias" |sed "\${transform}"\`
6217                                         fi
6218                                         cf_alias="\${cf_alias}\${extra_suffix}"
6219
6220                                         echo ".. \$verb alias \$cf_alias\${suffix}"
6221                                         rm -f "\$cf_alias\${suffix}"
6222                                 done
6223                         )
6224                 )
6225         else
6226 #               echo ".hy 0"
6227                 cat \$TMP
6228         fi
6229         ;;
6230 esac
6231 done
6232
6233 if test "$cf_manpage_inboth" = yes ; then
6234 if test "\$form" != format ; then
6235         $SHELL "\[$]0" format "\$verb" "\$mandir" "\$srcdir" "\[$]@"
6236 fi
6237 fi
6238
6239 exit 0
6240 CF_EOF
6241 chmod 755 "$cf_edit_man"
6242
6243 ])dnl
6244 dnl ---------------------------------------------------------------------------
6245 dnl CF_MAP_LIB_BASENAME version: 2 updated: 2021/01/02 17:09:14
6246 dnl -------------------
6247 dnl Convert a default-libname to the actual one used via CF_WITH_LIB_BASENAME.
6248 dnl
6249 dnl $1 = variable to set
6250 dnl $2 = default-libname
6251 AC_DEFUN([CF_MAP_LIB_BASENAME],[
6252 CF_UPPER(cf_map_lib_basename,$2)
6253 eval $1="\$${cf_map_lib_basename}_NAME"
6254 ])dnl
6255 dnl ---------------------------------------------------------------------------
6256 dnl CF_MATH_LIB version: 11 updated: 2022/07/27 19:01:48
6257 dnl -----------
6258 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
6259 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
6260 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
6261 AC_DEFUN([CF_MATH_LIB],
6262 [
6263 AC_CACHE_CHECK(if -lm needed for math functions,
6264         cf_cv_need_libm,[
6265         AC_TRY_LINK([
6266                 #include <stdio.h>
6267                 #include <stdlib.h>
6268                 #include <math.h>
6269         ],
6270         [double x = rand(); printf("result = %g\\n", ]ifelse([$2],,sin(x),$2)[)],
6271         [cf_cv_need_libm=no],
6272         [cf_cv_need_libm=yes])])
6273
6274 if test "$cf_cv_need_libm" = yes
6275 then
6276
6277         cf_save_LIBS="$LIBS"
6278         LIBS="$LIBS -lm"
6279         AC_CACHE_CHECK(if -lm is available for math functions,
6280         cf_cv_have_libm,[
6281         AC_TRY_LINK([
6282                 #include <stdio.h>
6283                 #include <stdlib.h>
6284                 #include <math.h>
6285         ],
6286         [double x = rand(); printf("result = %g\\n", ]ifelse([$2],,sin(x),$2)[)],
6287         [cf_cv_have_libm=yes],
6288         [cf_cv_have_libm=no])])
6289         LIBS="$cf_save_LIBS"
6290
6291         if test "$cf_cv_have_libm" = yes
6292         then
6293                 ifelse($1,,[CF_ADD_LIB(m)],[$1=-lm])
6294         fi
6295 else
6296         cf_cv_have_libm=yes
6297 fi
6298
6299 if test "$cf_cv_have_libm" = yes
6300 then
6301         AC_DEFINE(HAVE_MATH_FUNCS,1,[Define to 1 if math functions are available])
6302 fi
6303 ])
6304 dnl ---------------------------------------------------------------------------
6305 dnl CF_MIXEDCASE_FILENAMES version: 9 updated: 2021/01/01 16:53:59
6306 dnl ----------------------
6307 dnl Check if the file-system supports mixed-case filenames.  If we're able to
6308 dnl create a lowercase name and see it as uppercase, it doesn't support that.
6309 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
6310 [
6311 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
6312 if test "$cross_compiling" = yes ; then
6313         case "$target_alias" in
6314         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*|darwin*)
6315                 cf_cv_mixedcase=no
6316                 ;;
6317         (*)
6318                 cf_cv_mixedcase=yes
6319                 ;;
6320         esac
6321 else
6322         rm -f conftest CONFTEST
6323         echo test >conftest
6324         if test -f CONFTEST ; then
6325                 cf_cv_mixedcase=no
6326         else
6327                 cf_cv_mixedcase=yes
6328         fi
6329         rm -f conftest CONFTEST
6330 fi
6331 ])
6332 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
6333 ])dnl
6334 dnl ---------------------------------------------------------------------------
6335 dnl CF_MKSTEMP version: 12 updated: 2023/01/05 17:53:11
6336 dnl ----------
6337 dnl Check for a working mkstemp.  This creates two files, checks that they are
6338 dnl successfully created and distinct (AmigaOS apparently fails on the last).
6339 AC_DEFUN([CF_MKSTEMP],[
6340 AC_CHECK_HEADERS( \
6341 unistd.h \
6342 )
6343 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
6344 rm -rf ./conftest*
6345 AC_TRY_RUN([
6346 $ac_includes_default
6347
6348 int main(void)
6349 {
6350         char *tmpl = "conftestXXXXXX";
6351         char name[2][80];
6352         int n;
6353         int result = 0;
6354         int fd;
6355         struct stat sb;
6356
6357         umask(077);
6358         for (n = 0; n < 2; ++n) {
6359                 strcpy(name[n], tmpl);
6360                 if ((fd = mkstemp(name[n])) >= 0) {
6361                         if (!strcmp(name[n], tmpl)
6362                          || stat(name[n], &sb) != 0
6363                          || (sb.st_mode & S_IFMT) != S_IFREG
6364                          || (sb.st_mode & 077) != 0) {
6365                                 result = 1;
6366                         }
6367                         close(fd);
6368                 }
6369         }
6370         if (result == 0
6371          && !strcmp(name[0], name[1]))
6372                 result = 1;
6373         ${cf_cv_main_return:-return}(result);
6374 }
6375 ],[cf_cv_func_mkstemp=yes
6376 ],[cf_cv_func_mkstemp=no
6377 ],[cf_cv_func_mkstemp=maybe])
6378 ])
6379 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
6380         AC_CHECK_FUNC(mkstemp)
6381 fi
6382 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
6383         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
6384 fi
6385 ])dnl
6386 dnl ---------------------------------------------------------------------------
6387 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
6388 dnl ----------
6389 dnl Write a debug message to config.log, along with the line number in the
6390 dnl configure script.
6391 AC_DEFUN([CF_MSG_LOG],[
6392 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
6393 ])dnl
6394 dnl ---------------------------------------------------------------------------
6395 dnl CF_NCURSES_ABI_6 version: 5 updated: 2023/01/07 16:32:06
6396 dnl ----------------
6397 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
6398 dnl warn about this.
6399 AC_DEFUN([CF_NCURSES_ABI_6],[
6400 if test "${with_abi_version+set}" != set; then
6401         case "$cf_cv_rel_version" in
6402         (5.*)
6403                 cf_cv_rel_version=6.0
6404                 cf_cv_abi_version=6
6405                 cf_cv_abi_default=6
6406                 AC_MSG_WARN(overriding ABI version to $cf_cv_abi_default)
6407                 ;;
6408         esac
6409 fi
6410 ])dnl
6411 dnl ---------------------------------------------------------------------------
6412 dnl CF_NCURSES_WITH_ABI_VERSION version: 3 updated: 2021/01/01 13:31:04
6413 dnl ---------------------------
6414 dnl Allow ncurses's ABI to be overridden.  Generally this happens when a
6415 dnl packager has incremented the ABI past that used in the original package,
6416 dnl and wishes to keep doing this.
6417 dnl
6418 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
6419 dnl symbol.
6420 AC_DEFUN([CF_NCURSES_WITH_ABI_VERSION],[
6421 CF_WITH_ABI_VERSION($1)
6422 if test "x$cf_cv_abi_version" != "x$with_abi_version"
6423 then
6424         case "$cf_cv_rel_version" in
6425         (5.*)
6426                 cf_cv_rel_version=$with_abi_version.0
6427                 ;;
6428         esac
6429 fi
6430 ])dnl
6431 dnl ---------------------------------------------------------------------------
6432 dnl CF_NO_LEAKS_OPTION version: 9 updated: 2021/06/13 19:45:41
6433 dnl ------------------
6434 dnl see CF_WITH_NO_LEAKS
6435 dnl
6436 dnl $1 = option/name
6437 dnl $2 = help-text
6438 dnl $3 = symbol to define if the option is set
6439 dnl $4 = additional actions to take if the option is set
6440 AC_DEFUN([CF_NO_LEAKS_OPTION],[
6441 AC_MSG_CHECKING(if you want to use $1 for testing)
6442 AC_ARG_WITH($1,
6443         [$2],
6444         [case "x$withval" in
6445         (x|xno) ;;
6446         (*)
6447                 : "${with_cflags:=-g}"
6448                 : "${enable_leaks:=no}"
6449                 with_$1=yes
6450                 AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
6451          $4
6452 ])
6453                 ;;
6454         esac],
6455         [with_$1=])
6456 AC_MSG_RESULT(${with_$1:-no})
6457
6458 case ".$with_cflags" in
6459 (.*-g*)
6460         case .$CFLAGS in
6461         (.*-g*)
6462                 ;;
6463         (*)
6464                 CF_ADD_CFLAGS([-g])
6465                 ;;
6466         esac
6467         ;;
6468 esac
6469 ])dnl
6470 dnl ---------------------------------------------------------------------------
6471 dnl CF_NUMBER_SYNTAX version: 3 updated: 2023/05/06 16:14:29
6472 dnl ----------------
6473 dnl Check if the given variable is a positive integer.  Report an error if not.
6474 dnl $1 is the variable
6475 dnl $2 is the message
6476 AC_DEFUN([CF_NUMBER_SYNTAX],[
6477 if test -n "$1" ; then
6478   case `echo "$1" | sed -e 's/^[[0-9]]*$/0/g'` in
6479   (0)
6480         ;;
6481   (*)
6482         AC_MSG_ERROR($2 is not a number: $1)
6483         ;;
6484   esac
6485 else
6486   AC_MSG_ERROR($2 value is empty)
6487 fi
6488 ])dnl
6489 dnl ---------------------------------------------------------------------------
6490 dnl CF_OBJ_SUBDIR version: 8 updated: 2021/01/01 13:31:04
6491 dnl -------------
6492 dnl Compute the object-directory name from the given model name
6493 AC_DEFUN([CF_OBJ_SUBDIR],
6494 [
6495         case $1 in
6496         (libtool) $2='obj_lo'  ;;
6497         (normal)  $2='objects' ;;
6498         (debug)   $2='obj_g' ;;
6499         (profile) $2='obj_p' ;;
6500         (shared)
6501                 case "$cf_cv_system_name" in
6502                 (cygwin|msys)
6503                         $2='objects' ;;
6504                 (*)
6505                         $2='obj_s' ;;
6506                 esac
6507         esac
6508 ])dnl
6509 dnl ---------------------------------------------------------------------------
6510 dnl CF_OUTPUT_MANPAGE_RENAMES version: 2 updated: 2022/10/22 19:12:31
6511 dnl -------------------------
6512 dnl This runs in the output step to config.status, after man_db.renames has
6513 dnl been generated.
6514 AC_DEFUN([CF_OUTPUT_MANPAGE_RENAMES],
6515 [
6516 AC_REQUIRE([CF_MANPAGE_RENAMES])
6517 if test "$MANPAGE_RENAMES" != no ; then
6518         # Construct a sed-script to perform renaming within man-pages
6519         test -n "$verbose" && echo "creating edit_man.sed"
6520         test ! -d man && mkdir man
6521         FGREP="${FGREP-grep -F}" $SHELL "$srcdir/man/make_sed.sh" "$MANPAGE_RENAMES" >./edit_man.sed
6522 fi
6523 ])dnl
6524 dnl ---------------------------------------------------------------------------
6525 dnl CF_PATHSEP version: 8 updated: 2021/01/01 13:31:04
6526 dnl ----------
6527 dnl Provide a value for the $PATH and similar separator (or amend the value
6528 dnl as provided in autoconf 2.5x).
6529 AC_DEFUN([CF_PATHSEP],
6530 [
6531         AC_MSG_CHECKING(for PATH separator)
6532         case "$cf_cv_system_name" in
6533         (os2*)  PATH_SEPARATOR=';'  ;;
6534         (*)     ${PATH_SEPARATOR:=':'}  ;;
6535         esac
6536 ifelse([$1],,,[$1=$PATH_SEPARATOR])
6537         AC_SUBST(PATH_SEPARATOR)
6538         AC_MSG_RESULT($PATH_SEPARATOR)
6539 ])dnl
6540 dnl ---------------------------------------------------------------------------
6541 dnl CF_PATH_PROG version: 12 updated: 2021/01/02 09:31:20
6542 dnl ------------
6543 dnl Check for a given program, defining corresponding symbol.
6544 dnl     $1 = environment variable, which is suffixed by "_PATH" in the #define.
6545 dnl     $2 = program name to find.
6546 dnl     $3 = optional list of additional program names to test.
6547 dnl $4 = $PATH
6548 dnl
6549 dnl If there is more than one token in the result, #define the remaining tokens
6550 dnl to $1_ARGS.  We need this for 'install' in particular.
6551 dnl
6552 dnl FIXME: we should allow this to be overridden by environment variables
6553 dnl
6554 AC_DEFUN([CF_PATH_PROG],[
6555 AC_REQUIRE([CF_PATHSEP])
6556 test -z "[$]$1" && $1="$2"
6557 AC_PATH_PROGS($1,[$]$1 $2 ifelse($3,,,$3),[$]$1, ifelse($4,,,$4))
6558
6559 cf_path_prog=""
6560 cf_path_args=""
6561 IFS="${IFS:-    }"; cf_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR"
6562 for cf_temp in $ac_cv_path_$1
6563 do
6564         if test -z "$cf_path_prog" ; then
6565                 if test "$with_full_paths" = yes ; then
6566                         CF_PATH_SYNTAX(cf_temp,break)
6567                         cf_path_prog="$cf_temp"
6568                 else
6569                         cf_path_prog="`basename "$cf_temp"`"
6570                 fi
6571         elif test -z "$cf_path_args" ; then
6572                 cf_path_args="$cf_temp"
6573         else
6574                 cf_path_args="$cf_path_args $cf_temp"
6575         fi
6576 done
6577 IFS="$cf_save_ifs"
6578
6579 if test -n "$cf_path_prog" ; then
6580         CF_MSG_LOG(defining path for ${cf_path_prog})
6581         AC_DEFINE_UNQUOTED($1_PATH,"$cf_path_prog",Define to pathname $1)
6582         test -n "$cf_path_args" && AC_DEFINE_UNQUOTED($1_ARGS,"$cf_path_args",Define to provide args for $1)
6583 fi
6584 ])dnl
6585 dnl ---------------------------------------------------------------------------
6586 dnl CF_PATH_SYNTAX version: 18 updated: 2020/12/31 18:40:20
6587 dnl --------------
6588 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
6589 dnl begins with one of the prefix/exec_prefix variables, and then again if the
6590 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
6591 dnl delayed evaluation of those symbols.
6592 AC_DEFUN([CF_PATH_SYNTAX],[
6593 if test "x$prefix" != xNONE; then
6594         cf_path_syntax="$prefix"
6595 else
6596         cf_path_syntax="$ac_default_prefix"
6597 fi
6598
6599 case ".[$]$1" in
6600 (.\[$]\(*\)*|.\'*\'*)
6601         ;;
6602 (..|./*|.\\*)
6603         ;;
6604 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
6605         ;;
6606 (.\[$]\{*prefix\}*|.\[$]\{*dir\}*)
6607         eval $1="[$]$1"
6608         case ".[$]$1" in
6609         (.NONE/*)
6610                 $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
6611                 ;;
6612         esac
6613         ;;
6614 (.no|.NONE/*)
6615         $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
6616         ;;
6617 (*)
6618         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
6619         ;;
6620 esac
6621 ])dnl
6622 dnl ---------------------------------------------------------------------------
6623 dnl CF_PKG_CONFIG version: 12 updated: 2021/10/10 20:18:09
6624 dnl -------------
6625 dnl Check for the package-config program, unless disabled by command-line.
6626 dnl
6627 dnl Sets $PKG_CONFIG to the pathname of the pkg-config program.
6628 AC_DEFUN([CF_PKG_CONFIG],
6629 [
6630 AC_MSG_CHECKING(if you want to use pkg-config)
6631 AC_ARG_WITH(pkg-config,
6632         [  --with-pkg-config{=path} enable/disable use of pkg-config],
6633         [cf_pkg_config=$withval],
6634         [cf_pkg_config=yes])
6635 AC_MSG_RESULT($cf_pkg_config)
6636
6637 case "$cf_pkg_config" in
6638 (no)
6639         PKG_CONFIG=none
6640         ;;
6641 (yes)
6642         CF_ACVERSION_CHECK(2.52,
6643                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
6644                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
6645         ;;
6646 (*)
6647         PKG_CONFIG=$withval
6648         ;;
6649 esac
6650
6651 test -z "$PKG_CONFIG" && PKG_CONFIG=none
6652 if test "$PKG_CONFIG" != none ; then
6653         CF_PATH_SYNTAX(PKG_CONFIG)
6654 elif test "x$cf_pkg_config" != xno ; then
6655         AC_MSG_WARN(pkg-config is not installed)
6656 fi
6657
6658 AC_SUBST(PKG_CONFIG)
6659 ])dnl
6660 dnl ---------------------------------------------------------------------------
6661 dnl CF_POSIX_C_SOURCE version: 12 updated: 2023/02/18 17:41:25
6662 dnl -----------------
6663 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
6664 dnl
6665 dnl     POSIX.1-1990                            _POSIX_SOURCE
6666 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
6667 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
6668 dnl             Bindings Option
6669 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
6670 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
6671 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
6672 dnl
6673 dnl Parameters:
6674 dnl     $1 is the nominal value for _POSIX_C_SOURCE
6675 AC_DEFUN([CF_POSIX_C_SOURCE],
6676 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
6677
6678 if test "$cf_cv_posix_visible" = no; then
6679
6680 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
6681
6682 cf_save_CFLAGS="$CFLAGS"
6683 cf_save_CPPFLAGS="$CPPFLAGS"
6684
6685 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
6686 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
6687
6688 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
6689         CF_MSG_LOG(if the symbol is already defined go no further)
6690         AC_TRY_COMPILE([#include <sys/types.h>],[
6691 #ifndef _POSIX_C_SOURCE
6692 #error _POSIX_C_SOURCE is not defined
6693 #endif],
6694         [cf_cv_posix_c_source=no],
6695         [cf_want_posix_source=no
6696          case .$cf_POSIX_C_SOURCE in
6697          (.[[12]]??*)
6698                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
6699                 ;;
6700          (.2)
6701                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
6702                 cf_want_posix_source=yes
6703                 ;;
6704          (.*)
6705                 cf_want_posix_source=yes
6706                 ;;
6707          esac
6708          if test "$cf_want_posix_source" = yes ; then
6709                 AC_TRY_COMPILE([#include <sys/types.h>],[
6710 #ifdef _POSIX_SOURCE
6711 #error _POSIX_SOURCE is defined
6712 #endif],[],
6713                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
6714          fi
6715          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
6716          CFLAGS="$cf_trim_CFLAGS"
6717          CPPFLAGS="$cf_trim_CPPFLAGS"
6718          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
6719          CF_MSG_LOG(if the second compile does not leave our definition intact error)
6720          AC_TRY_COMPILE([#include <sys/types.h>],[
6721 #ifndef _POSIX_C_SOURCE
6722 #error _POSIX_C_SOURCE is not defined
6723 #endif],,
6724          [cf_cv_posix_c_source=no])
6725          CFLAGS="$cf_save_CFLAGS"
6726          CPPFLAGS="$cf_save_CPPFLAGS"
6727         ])
6728 ])
6729
6730 if test "$cf_cv_posix_c_source" != no ; then
6731         CFLAGS="$cf_trim_CFLAGS"
6732         CPPFLAGS="$cf_trim_CPPFLAGS"
6733         CF_ADD_CFLAGS($cf_cv_posix_c_source)
6734 fi
6735
6736 fi # cf_cv_posix_visible
6737
6738 ])dnl
6739 dnl ---------------------------------------------------------------------------
6740 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
6741 dnl ----------------
6742 dnl POSIX documents test-macros which an application may set before any system
6743 dnl headers are included to make features available.
6744 dnl
6745 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
6746 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
6747 dnl recent features visible in the system header files unless the application
6748 dnl overrides the corresponding test-macros.  Doing that introduces portability
6749 dnl problems.
6750 dnl
6751 dnl This macro makes a special check for the symbols used for this, to avoid a
6752 dnl conflicting definition.
6753 AC_DEFUN([CF_POSIX_VISIBLE],
6754 [
6755 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
6756 AC_TRY_COMPILE([#include <stdio.h>],[
6757 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
6758         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
6759         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
6760         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
6761 #error conflicting symbols found
6762 #endif
6763 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
6764 ])
6765 ])dnl
6766 dnl ---------------------------------------------------------------------------
6767 dnl CF_PREDEFINE version: 3 updated: 2023/02/18 17:41:25
6768 dnl ------------
6769 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
6770 dnl
6771 dnl $1 = symbol to test
6772 dnl $2 = value (if any) to use for a predefinition
6773 AC_DEFUN([CF_PREDEFINE],
6774 [
6775 AC_MSG_CHECKING(if we must define $1)
6776 AC_TRY_COMPILE([#include <sys/types.h>
6777 ],[
6778 #ifndef $1
6779 #error $1 is not defined
6780 #endif],[cf_result=no],[cf_result=yes])
6781 AC_MSG_RESULT($cf_result)
6782
6783 if test "$cf_result" = yes ; then
6784         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
6785 elif test "x$2" != "x" ; then
6786         AC_MSG_CHECKING(checking for compatible value versus $2)
6787         AC_TRY_COMPILE([#include <sys/types.h>
6788 ],[
6789 #if $1-$2 < 0
6790 #error $1-$2 is negative
6791 #endif],[cf_result=yes],[cf_result=no])
6792         AC_MSG_RESULT($cf_result)
6793         if test "$cf_result" = no ; then
6794                 # perhaps we can override it - try...
6795                 CPPFLAGS="$CPPFLAGS -D$1=$2"
6796         fi
6797 fi
6798 ])dnl
6799 dnl ---------------------------------------------------------------------------
6800 dnl CF_PRG_RULES version: 2 updated: 2021/01/01 13:31:04
6801 dnl ------------
6802 dnl Append definitions and rules for the given programs to the subdirectory
6803 dnl Makefiles, and the recursion rule for the top-level Makefile.
6804 dnl
6805 dnl parameters
6806 dnl     $1 = script to run
6807 dnl     $2 = list of subdirectories
6808 dnl
6809 dnl variables
6810 dnl     $AWK
6811 AC_DEFUN([CF_PRG_RULES],
6812 [
6813 for cf_dir in $2
6814 do
6815         if test ! -d "$srcdir/$cf_dir" ; then
6816                 continue
6817         elif test -f "$srcdir/$cf_dir/programs" ; then
6818                 $AWK -f $1 "$srcdir/$cf_dir/programs" >>$cf_dir/Makefile
6819         fi
6820 done
6821
6822 ])dnl
6823 dnl ---------------------------------------------------------------------------
6824 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
6825 dnl ----------
6826 dnl Check for archiver "ar".
6827 AC_DEFUN([CF_PROG_AR],[
6828 AC_CHECK_TOOL(AR, ar, ar)
6829 ])
6830 dnl ---------------------------------------------------------------------------
6831 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
6832 dnl -----------
6833 dnl Check for awk, ensure that the check found something.
6834 AC_DEFUN([CF_PROG_AWK],
6835 [
6836 AC_PROG_AWK
6837 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
6838 ])dnl
6839 dnl ---------------------------------------------------------------------------
6840 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
6841 dnl ----------
6842 dnl standard check for CC, plus followup sanity checks
6843 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
6844 AC_DEFUN([CF_PROG_CC],[
6845 CF_ACVERSION_CHECK(2.53,
6846         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
6847          AC_REQUIRE([AC_PROG_CC])],
6848         [])
6849 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
6850 CF_GCC_VERSION
6851 CF_ACVERSION_CHECK(2.52,
6852         [AC_PROG_CC_STDC],
6853         [CF_ANSI_CC_REQD])
6854 CF_CC_ENV_FLAGS
6855 ])dnl
6856 dnl ---------------------------------------------------------------------------
6857 dnl CF_PROG_CC_C_O version: 6 updated: 2021/01/01 13:31:04
6858 dnl --------------
6859 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
6860 dnl the output file can be renamed, and allows for a shell variable that can
6861 dnl be used later.  The parameter is either CC or CXX.  The result is the
6862 dnl cache variable:
6863 dnl     $cf_cv_prog_CC_c_o
6864 dnl     $cf_cv_prog_CXX_c_o
6865 dnl
6866 dnl $1 = compiler
6867 dnl $2 = compiler options, if any
6868 AC_DEFUN([CF_PROG_CC_C_O],
6869 [AC_REQUIRE([AC_PROG_CC])dnl
6870 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
6871 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
6872 [
6873 cat > conftest.$ac_ext <<CF_EOF
6874 int main(void)
6875 {
6876         ${cf_cv_main_return:-return}(0);
6877 }
6878 CF_EOF
6879 # We do the test twice because some compilers refuse to overwrite an
6880 # existing .o file with -o, though they will create one.
6881 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
6882 if AC_TRY_EVAL(ac_try) &&
6883   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
6884 then
6885   eval cf_cv_prog_$1_c_o=yes
6886 else
6887   eval cf_cv_prog_$1_c_o=no
6888 fi
6889 rm -rf ./conftest*
6890 ])dnl
6891 if test "$cf_cv_prog_$1_c_o" = yes; then
6892   AC_MSG_RESULT([yes])
6893 else
6894   AC_MSG_RESULT([no])
6895 fi
6896 ])dnl
6897 dnl ---------------------------------------------------------------------------
6898 dnl CF_PROG_GNAT version: 12 updated: 2021/01/02 17:09:14
6899 dnl ------------
6900 dnl Check for gnat/gnatmake/etc, ensure that the toolset is complete.
6901 AC_DEFUN([CF_PROG_GNAT],[
6902 for cf_prog_gnat in gnat gnatmake gprconfig gprbuild
6903 do
6904         CF_UPPER(cf_upper_prog_gnat,${cf_prog_gnat})
6905
6906         unset ac_cv_path_cf_TEMP_gnat
6907         unset cf_TEMP_gnat
6908         AC_PATH_PROG(cf_TEMP_gnat,$cf_prog_gnat,no)
6909         eval "cf_cv_PATH_$cf_upper_prog_gnat=[$]ac_cv_path_cf_TEMP_gnat"
6910
6911         if test "x$cf_TEMP_gnat" != xno; then
6912                 unset cf_cv_gnat_version
6913                 unset cf_TEMP_gnat
6914                 CF_GNAT_VERSION(cf_TEMP_gnat,$cf_prog_gnat)
6915         fi
6916         eval "cf_cv_VERSION_$cf_upper_prog_gnat=[$]cf_TEMP_gnat"
6917
6918         unset cf_TEMP_gnat
6919         unset cf_cv_gnat_version
6920         unset ac_cv_path_cf_TEMP_gnat
6921 done
6922
6923 if test "x$cf_cv_VERSION_GNATMAKE" = "xno"; then
6924         cf_ada_make=
6925         cf_cv_prog_gnat_correct=no
6926 else
6927         cf_ada_make=gnatmake
6928         if test "x$cf_cv_VERSION_GPRCONFIG" = "xno"; then
6929                 # gprconfig is newer than gnatmake; we can continue...
6930                 cf_ada_config="##"
6931         else
6932                 rm -rf ./conftest* ./*~conftest*
6933                 if mkdir conftest.src
6934                 then
6935                         cf_ada_config=""
6936                         cd conftest.src
6937                         for cf_gprconfig in Ada C
6938                         do
6939                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
6940                                 if test "$cf_gprconfig" = C
6941                                 then
6942                                         for cf_gprconfig_param in \
6943                                                 "$cf_gprconfig,,,,GNATGCC" \
6944                                                 "$cf_gprconfig,,,,GCC" \
6945                                                 "$cf_gprconfig"
6946                                         do
6947                                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6948                                                 test -n "$cf_gprconfig_value" && break
6949                                         done
6950                                 else
6951                                         cf_gprconfig_param=$cf_gprconfig
6952                                         cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6953                                 fi
6954                                 if test -n "$cf_gprconfig_value"
6955                                 then
6956                                         eval "cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value"
6957                                         AC_MSG_RESULT($cf_gprconfig_value)
6958                                 else
6959                                         AC_MSG_RESULT(missing)
6960                                         cf_ada_config="#"
6961                                         break
6962                                 fi
6963                         done
6964                         cd ..
6965                         rm -rf ./conftest* ./*~conftest*
6966                 fi
6967         fi
6968         if test "x$cf_ada_config" != "x#"
6969         then
6970                 CF_GNAT_VERSION
6971                 CF_CHECK_GNAT_VERSION
6972                 AC_CHECK_PROG(M4_exists, m4, yes, no)
6973                 if test "$ac_cv_prog_M4_exists" = no; then
6974                         cf_cv_prog_gnat_correct=no
6975                         AC_MSG_WARN(Ada95 binding required program m4 not found. Ada95 binding disabled)
6976                 fi
6977                 if test "$cf_cv_prog_gnat_correct" = yes; then
6978                         AC_MSG_CHECKING(if GNAT works)
6979                         CF_GNAT_TRY_RUN([procedure conftest;],
6980 [with Text_IO;
6981 with GNAT.OS_Lib;
6982 procedure conftest is
6983 begin
6984    Text_IO.Put ("Hello World");
6985    Text_IO.New_Line;
6986    GNAT.OS_Lib.OS_Exit (0);
6987 end conftest;],
6988 [cf_cv_prog_gnat_correct=yes],
6989 [cf_cv_prog_gnat_correct=no])
6990                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
6991                 fi
6992         else
6993                 cf_cv_prog_gnat_correct=no
6994         fi
6995 fi
6996
6997 AC_SUBST(cf_ada_make)
6998 AC_SUBST(cf_ada_config)
6999 AC_SUBST(cf_ada_config_Ada)
7000 AC_SUBST(cf_ada_config_C)
7001 ])dnl
7002 dnl ---------------------------------------------------------------------------
7003 dnl CF_PROG_INSTALL version: 10 updated: 2021/01/04 19:33:05
7004 dnl ---------------
7005 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
7006 dnl misc/tabset install won't work properly.  Usually this happens only when
7007 dnl using the fallback mkinstalldirs script
7008 AC_DEFUN([CF_PROG_INSTALL],
7009 [AC_PROG_INSTALL
7010 case $INSTALL in
7011 (/*)
7012         ;;
7013 (*)
7014         CF_DIRNAME(cf_dir,$INSTALL)
7015         test -z "$cf_dir" && cf_dir=.
7016         INSTALL="`cd \"$cf_dir\" && pwd`"/"`echo "$INSTALL" | sed -e 's%^.*/%%'`"
7017         ;;
7018 esac
7019 ])dnl
7020 dnl ---------------------------------------------------------------------------
7021 dnl CF_PROG_LDCONFIG version: 5 updated: 2015/04/18 08:56:57
7022 dnl ----------------
7023 dnl Check for ldconfig, needed to fixup shared libraries that would be built
7024 dnl and then used in the install.
7025 AC_DEFUN([CF_PROG_LDCONFIG],[
7026 if test "$cross_compiling" = yes ; then
7027         LDCONFIG=:
7028 else
7029         case "$cf_cv_system_name" in
7030         (dragonfly*|mirbsd*|freebsd*)
7031                 test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
7032                 ;;
7033         (*) LDPATH=$PATH:/sbin:/usr/sbin
7034                 AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
7035                 ;;
7036         esac
7037 fi
7038 AC_SUBST(LDCONFIG)
7039 ])dnl
7040 dnl ---------------------------------------------------------------------------
7041 dnl CF_PROG_LINT version: 5 updated: 2022/08/20 15:44:13
7042 dnl ------------
7043 AC_DEFUN([CF_PROG_LINT],
7044 [
7045 AC_CHECK_PROGS(LINT, lint cppcheck splint)
7046 case "x$LINT" in
7047 (xcppcheck|x*/cppcheck)
7048         test -z "$LINT_OPTS" && LINT_OPTS="--enable=all"
7049         ;;
7050 esac
7051 AC_SUBST(LINT_OPTS)
7052 AC_SUBST(LINT_LIBS)
7053 ])dnl
7054 dnl ---------------------------------------------------------------------------
7055 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
7056 dnl ------------
7057 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
7058 dnl option if it is supported.
7059 AC_DEFUN([CF_PROG_LN_S],[
7060 AC_PROG_LN_S
7061 AC_MSG_CHECKING(if $LN_S -f options work)
7062
7063 rm -f conf$$.src conf$$dst
7064 echo >conf$$.dst
7065 echo first >conf$$.src
7066 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
7067         cf_prog_ln_sf=yes
7068 else
7069         cf_prog_ln_sf=no
7070 fi
7071 rm -f conf$$.dst conf$$src
7072 AC_MSG_RESULT($cf_prog_ln_sf)
7073
7074 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
7075 ])dnl
7076 dnl ---------------------------------------------------------------------------
7077 dnl CF_REGEX version: 18 updated: 2021/01/01 16:53:59
7078 dnl --------
7079 dnl Attempt to determine if we've got one of the flavors of regular-expression
7080 dnl code that we can support.
7081 AC_DEFUN([CF_REGEX],
7082 [
7083
7084 cf_regex_func=no
7085 cf_regex_libs=
7086 case "$host_os" in
7087 (mingw*)
7088         # -lsystre -ltre -lintl -liconv
7089         AC_CHECK_LIB(systre,regcomp,[
7090                 AC_CHECK_LIB(iconv,libiconv_open,[CF_ADD_LIB(iconv)])
7091                 AC_CHECK_LIB(intl,libintl_gettext,[CF_ADD_LIB(intl)])
7092                 AC_CHECK_LIB(tre,tre_regcomp,[CF_ADD_LIB(tre)])
7093                 CF_ADD_LIB(systre)
7094                 cf_regex_func=regcomp
7095         ],[
7096                 AC_CHECK_LIB(gnurx,regcomp,[
7097                         CF_ADD_LIB(gnurx)
7098                         cf_regex_func=regcomp])
7099         ])
7100         ;;
7101 (*)
7102         cf_regex_libs="regex re"
7103         AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
7104                 for cf_regex_lib in $cf_regex_libs
7105                 do
7106                         AC_CHECK_LIB($cf_regex_lib,regcomp,[
7107                                         CF_ADD_LIB($cf_regex_lib)
7108                                         cf_regex_func=regcomp
7109                                         break])
7110                 done
7111         ])
7112         ;;
7113 esac
7114
7115 if test "$cf_regex_func" = no ; then
7116         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
7117                 AC_CHECK_LIB(gen,compile,[
7118                                 CF_ADD_LIB(gen)
7119                                 cf_regex_func=compile])])
7120 fi
7121
7122 if test "$cf_regex_func" = no ; then
7123         AC_MSG_WARN(cannot find regular expression library)
7124 fi
7125
7126 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
7127
7128 cf_cv_regex_hdrs=no
7129 case "$cf_regex_func" in
7130 (compile)
7131         for cf_regex_hdr in regexp.h regexpr.h
7132         do
7133                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
7134                         char *p = compile("", "", "", 0);
7135                         int x = step("", "");
7136                         (void)p;
7137                         (void)x;
7138                 ],[
7139                         cf_cv_regex_hdrs=$cf_regex_hdr
7140                         break
7141                 ])
7142         done
7143         ;;
7144 (*)
7145         for cf_regex_hdr in regex.h
7146         do
7147                 AC_TRY_LINK([#include <sys/types.h>
7148 #include <$cf_regex_hdr>],[
7149                         regex_t *p = 0;
7150                         int x = regcomp(p, "", 0);
7151                         int y = regexec(p, "", 0, 0, 0);
7152                         (void)x;
7153                         (void)y;
7154                         regfree(p);
7155                 ],[
7156                         cf_cv_regex_hdrs=$cf_regex_hdr
7157                         break
7158                 ])
7159         done
7160         ;;
7161 esac
7162
7163 ])
7164
7165 case "$cf_cv_regex_hdrs" in
7166         (no)            AC_MSG_WARN(no regular expression header found) ;;
7167         (regex.h)       AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;;
7168         (regexp.h)      AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;;
7169         (regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
7170 esac
7171 ])dnl
7172 dnl ---------------------------------------------------------------------------
7173 dnl CF_REMOVE_CFLAGS version: 3 updated: 2021/09/05 17:25:40
7174 dnl ----------------
7175 dnl Remove a given option from CFLAGS/CPPFLAGS
7176 dnl $1 = option to remove
7177 dnl $2 = variable to update
7178 dnl $3 = nonempty to allow verbose message
7179 define([CF_REMOVE_CFLAGS],
7180 [
7181 cf_tmp_cflag=`echo "x$1" | sed -e 's/^.//' -e 's/=.*//'`
7182 while true
7183 do
7184         cf_old_cflag=`echo "x[$]$2" | sed -e 's/^.//' -e 's/[[  ]][[    ]]*-/ -/g' -e "s%$cf_tmp_cflag\\(=[[^   ]][[^   ]]*\\)\?%%" -e 's/^[[   ]]*//' -e 's%[[ ]][[ ]]*-D% -D%g' -e 's%[[ ]][[ ]]*-I% -I%g'`
7185         test "[$]$2" != "$cf_old_cflag" || break
7186         ifelse([$3],,,[CF_VERBOSE(removing old option $1 from $2)])
7187         $2="$cf_old_cflag"
7188 done
7189 ])dnl
7190 dnl ---------------------------------------------------------------------------
7191 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
7192 dnl ----------------
7193 dnl Remove all -U and -D options that refer to the given symbol from a list
7194 dnl of C compiler options.  This works around the problem that not all
7195 dnl compilers process -U and -D options from left-to-right, so a -U option
7196 dnl cannot be used to cancel the effect of a preceding -D option.
7197 dnl
7198 dnl $1 = target (which could be the same as the source variable)
7199 dnl $2 = source (including '$')
7200 dnl $3 = symbol to remove
7201 define([CF_REMOVE_DEFINE],
7202 [
7203 $1=`echo "$2" | \
7204         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
7205                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
7206 ])dnl
7207 dnl ---------------------------------------------------------------------------
7208 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
7209 dnl -------------
7210 dnl Remove the given library from the symbol
7211 dnl
7212 dnl $1 = target (which could be the same as the source variable)
7213 dnl $2 = source (including '$')
7214 dnl $3 = library to remove
7215 define([CF_REMOVE_LIB],
7216 [
7217 # remove $3 library from $2
7218 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
7219 ])dnl
7220 dnl ---------------------------------------------------------------------------
7221 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
7222 dnl ---------------------
7223 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
7224 dnl $1 = name of current macro
7225 define([CF_RESTORE_XTRA_FLAGS],
7226 [
7227 LIBS="$cf_save_LIBS_$1"
7228 CFLAGS="$cf_save_CFLAGS_$1"
7229 CPPFLAGS="$cf_save_CPPFLAGS_$1"
7230 ])dnl
7231 dnl ---------------------------------------------------------------------------
7232 dnl CF_RPATH_HACK version: 13 updated: 2021/01/03 18:30:50
7233 dnl -------------
7234 AC_DEFUN([CF_RPATH_HACK],
7235 [AC_REQUIRE([AC_PROG_FGREP])dnl
7236 AC_REQUIRE([CF_LD_RPATH_OPT])dnl
7237
7238 AC_MSG_CHECKING(for updated LDFLAGS)
7239 if test -n "$LD_RPATH_OPT" ; then
7240         AC_MSG_RESULT(maybe)
7241
7242         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
7243         cf_rpath_list="/usr/lib /lib"
7244         if test "$cf_ldd_prog" != no
7245         then
7246                 cf_rpath_oops=
7247
7248 AC_TRY_LINK([#include <stdio.h>],
7249                 [printf("Hello");],
7250                 [cf_rpath_oops=`"$cf_ldd_prog" "conftest$ac_exeext" | ${FGREP-fgrep} ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
7251                  cf_rpath_list=`"$cf_ldd_prog" "conftest$ac_exeext" | ${FGREP-fgrep} / | sed -e 's%^.*[[        ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
7252
7253                 # If we passed the link-test, but get a "not found" on a given library,
7254                 # this could be due to inept reconfiguration of gcc to make it only
7255                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
7256                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
7257                 # /usr/local libraries.
7258                 if test -n "$cf_rpath_oops"
7259                 then
7260                         for cf_rpath_src in $cf_rpath_oops
7261                         do
7262                                 for cf_rpath_dir in \
7263                                         /usr/local \
7264                                         /usr/pkg \
7265                                         /opt/sfw
7266                                 do
7267                                         if test -f "$cf_rpath_dir/lib/$cf_rpath_src"
7268                                         then
7269                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
7270                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
7271                                                 break
7272                                         fi
7273                                 done
7274                         done
7275                 fi
7276         fi
7277
7278         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
7279
7280         CF_RPATH_HACK_2(LDFLAGS)
7281         CF_RPATH_HACK_2(LIBS)
7282
7283         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
7284 else
7285         AC_MSG_RESULT(no)
7286 fi
7287 AC_SUBST(EXTRA_LDFLAGS)
7288 ])dnl
7289 dnl ---------------------------------------------------------------------------
7290 dnl CF_RPATH_HACK_2 version: 8 updated: 2021/01/01 13:31:04
7291 dnl ---------------
7292 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
7293 dnl EXTRA_LDFLAGS for each -L option found.
7294 dnl
7295 dnl $cf_rpath_list contains a list of directories to ignore.
7296 dnl
7297 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
7298 dnl      but LIBS often has misplaced -L options.
7299 AC_DEFUN([CF_RPATH_HACK_2],
7300 [
7301 CF_VERBOSE(...checking $1 [$]$1)
7302
7303 cf_rpath_dst=
7304 for cf_rpath_src in [$]$1
7305 do
7306         case "$cf_rpath_src" in
7307         (-L*)
7308
7309                 # check if this refers to a directory which we will ignore
7310                 cf_rpath_skip=no
7311                 if test -n "$cf_rpath_list"
7312                 then
7313                         for cf_rpath_item in $cf_rpath_list
7314                         do
7315                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
7316                                 then
7317                                         cf_rpath_skip=yes
7318                                         break
7319                                 fi
7320                         done
7321                 fi
7322
7323                 if test "$cf_rpath_skip" = no
7324                 then
7325                         # transform the option
7326                         if test "$LD_RPATH_OPT" = "-R " ; then
7327                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
7328                         else
7329                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
7330                         fi
7331
7332                         # if we have not already added this, add it now
7333                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
7334                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
7335                         then
7336                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
7337                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
7338                         fi
7339                 fi
7340                 ;;
7341         esac
7342         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
7343 done
7344 $1=$cf_rpath_dst
7345
7346 CF_VERBOSE(...checked $1 [$]$1)
7347 AC_SUBST(EXTRA_LDFLAGS)
7348 ])dnl
7349 dnl ---------------------------------------------------------------------------
7350 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
7351 dnl ------------------
7352 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
7353 dnl and libraries which do not update those variables.
7354 dnl
7355 dnl $1 = name of current macro
7356 define([CF_SAVE_XTRA_FLAGS],
7357 [
7358 cf_save_LIBS_$1="$LIBS"
7359 cf_save_CFLAGS_$1="$CFLAGS"
7360 cf_save_CPPFLAGS_$1="$CPPFLAGS"
7361 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
7362 for cf_X_CFLAGS in $X_CFLAGS
7363 do
7364         case "x$cf_X_CFLAGS" in
7365         x-[[IUD]]*)
7366                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
7367                 ;;
7368         *)
7369                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
7370                 ;;
7371         esac
7372 done
7373 ])dnl
7374 dnl ---------------------------------------------------------------------------
7375 dnl CF_SHARED_OPTS version: 107 updated: 2021/09/04 06:47:34
7376 dnl --------------
7377 dnl --------------
7378 dnl Attempt to determine the appropriate CC/LD options for creating a shared
7379 dnl library.
7380 dnl
7381 dnl Notes:
7382 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
7383 dnl the build-tree, i.e., by making use of the libraries that are compiled in
7384 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
7385 dnl shared library since that can lead to unexpected results at runtime.
7386 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
7387 dnl libraries are compiled in ../../lib
7388 dnl
7389 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
7390 dnl to install symbolic links to the rel/abi versions of shared libraries.
7391 dnl
7392 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
7393 dnl version when making symbolic links.
7394 dnl
7395 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
7396 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
7397 dnl (ex: libncurses.so.<ver>).
7398 dnl
7399 dnl Some loaders leave 'so_locations' lying around.  It is nice to clean up.
7400 AC_DEFUN([CF_SHARED_OPTS],
7401 [
7402         AC_REQUIRE([CF_LD_RPATH_OPT])
7403
7404         RM_SHARED_OPTS=
7405         LOCAL_LDFLAGS=
7406         LOCAL_LDFLAGS2=
7407         LD_SHARED_OPTS=
7408         INSTALL_LIB="-m 644"
7409         : ${rel_builddir:=.}
7410
7411         shlibdir=$libdir
7412         AC_SUBST(shlibdir)
7413
7414         MAKE_DLLS="#"
7415         AC_SUBST(MAKE_DLLS)
7416
7417         cf_cv_do_symlinks=no
7418         cf_ld_rpath_opt=
7419         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
7420
7421         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
7422         AC_ARG_WITH(shlib-version,
7423         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
7424         [test -z "$withval" && withval=auto
7425         case "$withval" in
7426         (yes)
7427                 cf_cv_shlib_version=auto
7428                 ;;
7429         (rel|abi|auto)
7430                 cf_cv_shlib_version=$withval
7431                 ;;
7432         (*)
7433                 AC_MSG_RESULT($withval)
7434                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
7435                 ;;
7436         esac
7437         ],[cf_cv_shlib_version=auto])
7438         AC_MSG_RESULT($cf_cv_shlib_version)
7439
7440         cf_cv_rm_so_locs=no
7441         cf_try_cflags=
7442
7443         # Some less-capable ports of gcc support only -fpic
7444         CC_SHARED_OPTS=
7445
7446         cf_try_fPIC=no
7447         if test "$GCC" = yes
7448         then
7449                 cf_try_fPIC=yes
7450         else
7451                 case "$cf_cv_system_name" in
7452                 (*linux*)       # e.g., PGI compiler
7453                         cf_try_fPIC=yes
7454                         ;;
7455                 esac
7456         fi
7457
7458         if test "$cf_try_fPIC" = yes
7459         then
7460                 AC_MSG_CHECKING(which $CC option to use)
7461                 cf_save_CFLAGS="$CFLAGS"
7462                 for CC_SHARED_OPTS in -fPIC -fpic ''
7463                 do
7464                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
7465                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
7466                 done
7467                 AC_MSG_RESULT($CC_SHARED_OPTS)
7468                 CFLAGS="$cf_save_CFLAGS"
7469         fi
7470
7471         cf_cv_shlib_version_infix=no
7472
7473         case "$cf_cv_system_name" in
7474         (aix4.[3-9]*|aix[[5-7]]*)
7475                 if test "$GCC" = yes; then
7476                         CC_SHARED_OPTS='-Wl,-brtl'
7477                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
7478                 else
7479                         CC_SHARED_OPTS='-brtl'
7480                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
7481                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
7482                 fi
7483                 ;;
7484         (beos*)
7485                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
7486                 ;;
7487         (cygwin*)
7488                 CC_SHARED_OPTS=
7489                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
7490                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
7491                 cf_cv_shlib_version=cygdll
7492                 cf_cv_shlib_version_infix=cygdll
7493                 shlibdir=$bindir
7494                 MAKE_DLLS=
7495                 cat >mk_shared_lib.sh <<-CF_EOF
7496                 #!$SHELL
7497                 SHARED_LIB=\[$]1
7498                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
7499                 shift
7500                 cat <<-EOF
7501                 Linking shared library
7502                 ** SHARED_LIB \[$]SHARED_LIB
7503                 ** IMPORT_LIB \[$]IMPORT_LIB
7504 EOF
7505                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7506 CF_EOF
7507                 chmod +x mk_shared_lib.sh
7508                 ;;
7509         (msys*)
7510                 CC_SHARED_OPTS=
7511                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
7512                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
7513                 cf_cv_shlib_version=msysdll
7514                 cf_cv_shlib_version_infix=msysdll
7515                 shlibdir=$bindir
7516                 MAKE_DLLS=
7517                 cat >mk_shared_lib.sh <<-CF_EOF
7518                 #!$SHELL
7519                 SHARED_LIB=\[$]1
7520                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
7521                 shift
7522                 cat <<-EOF
7523                 Linking shared library
7524                 ** SHARED_LIB \[$]SHARED_LIB
7525                 ** IMPORT_LIB \[$]IMPORT_LIB
7526 EOF
7527                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7528 CF_EOF
7529                 chmod +x mk_shared_lib.sh
7530                 ;;
7531         (darwin*)
7532                 cf_try_cflags="no-cpp-precomp"
7533                 CC_SHARED_OPTS="-dynamic"
7534                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
7535                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
7536                 cf_cv_shlib_version_infix=yes
7537                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
7538                         cf_save_LDFLAGS=$LDFLAGS
7539                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
7540                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
7541                                 LDFLAGS=$cf_save_LDFLAGS])
7542                 if test "$cf_cv_ldflags_search_paths_first" = yes; then
7543                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
7544                 fi
7545                 ;;
7546         (haiku*)
7547                 CF_SHARED_SONAME
7548                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7549                 ;;
7550         (hpux[[7-8]]*)
7551                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
7552                 if test "$GCC" != yes; then
7553                         CC_SHARED_OPTS='+Z'
7554                 fi
7555                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
7556                 INSTALL_LIB="-m 555"
7557                 ;;
7558         (hpux*)
7559                 # (tested with gcc 2.7.2 -- I don't have c89)
7560                 if test "$GCC" = yes; then
7561                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
7562                 else
7563                         CC_SHARED_OPTS='+Z'
7564                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
7565                 fi
7566                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
7567                 # HP-UX shared libraries must be executable, and should be
7568                 # readonly to exploit a quirk in the memory manager.
7569                 INSTALL_LIB="-m 555"
7570                 ;;
7571         (interix*)
7572                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7573                 if test "$cf_cv_shlib_version" = rel; then
7574                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
7575                 else
7576                         cf_shared_soname='`basename $[@]`'
7577                 fi
7578                 CC_SHARED_OPTS=
7579                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
7580                 ;;
7581         (irix*)
7582                 if test "$cf_cv_enable_rpath" = yes ; then
7583                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7584                 fi
7585                 # tested with IRIX 5.2 and 'cc'.
7586                 if test "$GCC" != yes; then
7587                         CC_SHARED_OPTS='-KPIC'
7588                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
7589                 else
7590                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
7591                 fi
7592                 cf_cv_rm_so_locs=yes
7593                 ;;
7594         (linux*|gnu*|k*bsd*-gnu)
7595                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7596                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7597                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7598                 fi
7599                 if test "$cf_cv_enable_rpath" = yes ; then
7600                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7601                 fi
7602                 CF_SHARED_SONAME
7603                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7604                 ;;
7605         (mingw*msvc*)
7606                 cf_cv_shlib_version=msvcdll
7607                 cf_cv_shlib_version_infix=msvcdll
7608                 shlibdir=$bindir
7609                 MAKE_DLLS=
7610                 if test "$DFT_LWR_MODEL" = "shared" ; then
7611                         LOCAL_LDFLAGS="-link -dll"
7612                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7613                         EXTRA_LDFLAGS="-link -dll $EXTRA_LDFLAGS"
7614                 fi
7615                 CC_SHARED_OPTS=
7616                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ ${LD} [$]{CFLAGS}'
7617                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.lib"
7618                 cat >mk_shared_lib.sh <<-CF_EOF
7619                 #!$SHELL
7620                 SHARED_LIB=\[$]1
7621                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.lib/'\`
7622                 shift
7623                 my_ld=\[$]1
7624                 shift
7625                 cat <<-EOF
7626                 Linking shared library
7627                 ** SHARED LIB \$SHARED_LIB
7628                 ** IMPORT_LIB \$IMPORT_LIB
7629 EOF
7630                 args=\$(echo \[$]* | sed -E "s#-l(\w*)#\1.dll.lib#g" | sed -E "s#-L(\w*)#-LIBPATH:\1#g")
7631                 exec \$my_ld -DLL -IMPLIB:"\${IMPORT_LIB}" -OUT:"\${SHARED_LIB}" ${LDFLAGS} \$args
7632                 mv "\${IMPORT_LIB}" "\${IMPORT_LIB}"
7633 CF_EOF
7634                 chmod +x mk_shared_lib.sh
7635                 cat >mk_prog.sh <<-CF_EOF
7636                 #!$SHELL
7637                 shift
7638                 # Ignore first argument (compiler) and use LD (link.exe) unconditionally
7639                 LD="[$]LD"
7640                 clopts=()
7641                 ldopts=("/subsystem:console")
7642                 libs=()
7643                 isdll=0
7644                 while test \[$]# -gt 0; do
7645                         case "\[$]1" in
7646                                 -link)
7647                                         # ignore -link argument
7648                                         ;;
7649                                 -M[[TD]] | -M[[TD]]d)
7650                                         # ignore runtime-library option
7651                                         ;;
7652                                 -dll)
7653                                         isdll=1
7654                                         ;;
7655                                 -W* | -w*)
7656                                         # ignore warnings
7657                                         ;;
7658                                 -D*)
7659                                         clopts+=("\[$]1")
7660                                         ;;
7661                                 -I*)
7662                                         clopts+=("\[$]1")
7663                                         ;;
7664                                 -l*)
7665                                         libs+=("\`echo \"\[$]1\" | sed \"s/^-l//\"\`")
7666                                         ;;
7667                                 -L*)
7668                                         ldopts+=("\`echo \"\[$]1\" | sed \"s/^-L/-LIBPATH:/\"\`")
7669                                         ;;
7670                                 *.obj | *.o)
7671                                         ldopts+=("\[$]1")
7672                                         ;;
7673                                 -Wl,*)
7674                                         for linkarg in \`echo '\[$]1' | sed -e 's/-Wl,//' -e 's/,/ /'\`; do
7675                                                 ldopts+=("\[$]{linkarg}")
7676                                         done
7677                                         ;;
7678                                 *.lib)
7679                                         ldopts+=("\[$]1")
7680                                         ;;
7681                                 -o)
7682                                         shift
7683                                         ldopts+=("-out:\[$]1")
7684                                         ;;
7685                                 *)
7686                                         clopts+=("\[$]1")
7687                                         ldopts+=("\[$]1")
7688                                         ;;
7689                         esac
7690                         shift
7691                 done
7692                 if [[ "\$isdll" -ne 0 ]]; then
7693                         for lib in \[$]{libs[[*]]}; do
7694                                 ldopts+=("\[$]lib.dll.lib")
7695                         done
7696                 else
7697                         for lib in \[$]{libs[[*]]}; do
7698                                 ldopts+=("\[$]lib.lib")
7699                         done
7700                 fi
7701                 cat <<-EOF
7702                 Creating program
7703                 ** ld options:   "\[$]{ldopts[[@]]}"
7704 EOF
7705                 exec \[$]LD \[$]{ldopts[[@]]}
7706 CF_EOF
7707                 chmod +x mk_prog.sh
7708                 LINK_PROGS="$SHELL ${rel_builddir}/mk_prog.sh"
7709                 LINK_TESTS="$SHELL ${rel_builddir}/mk_prog.sh"
7710                 ;;
7711         (mingw*)
7712                 cf_cv_shlib_version=mingw
7713                 cf_cv_shlib_version_infix=mingw
7714                 shlibdir=$bindir
7715                 MAKE_DLLS=
7716                 if test "$DFT_LWR_MODEL" = "shared" ; then
7717                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
7718                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7719                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
7720                 fi
7721                 CC_SHARED_OPTS=
7722                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
7723                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
7724                 cat >mk_shared_lib.sh <<-CF_EOF
7725                 #!$SHELL
7726                 SHARED_LIB=\[$]1
7727                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
7728                 shift
7729                 cat <<-EOF
7730                 Linking shared library
7731                 ** SHARED_LIB \[$]SHARED_LIB
7732                 ** IMPORT_LIB \[$]IMPORT_LIB
7733 EOF
7734                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7735 CF_EOF
7736                 chmod +x mk_shared_lib.sh
7737                 ;;
7738         (openbsd[[2-9]].*|mirbsd*)
7739                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7740                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7741                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7742                 fi
7743                 if test "$cf_cv_enable_rpath" = yes ; then
7744                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7745                 fi
7746                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7747                 CF_SHARED_SONAME
7748                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7749                 ;;
7750         (nskJ*)
7751                 CC_SHARED_OPTS=
7752                 MK_SHARED_LIB='${LD} -Wshared -Weld=-export_all -o $[@]'
7753                 ;;
7754         (nskL*)
7755                 CC_SHARED_OPTS=
7756                 MK_SHARED_LIB='${LD} -Wshared -Wxld=-export_all -o $[@]'
7757                 ;;
7758         (nto-qnx*|openbsd*|freebsd[[12]].*)
7759                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7760                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
7761                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7762                 ;;
7763         (dragonfly*|freebsd*)
7764                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7765                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
7766                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
7767                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
7768                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7769                 fi
7770                 CF_SHARED_SONAME
7771                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7772                 ;;
7773         (netbsd*)
7774                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7775                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
7776                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
7777                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7778                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7779                         if test "$cf_cv_shlib_version" = auto; then
7780                         if test -f /usr/libexec/ld.elf_so; then
7781                                 cf_cv_shlib_version=abi
7782                         else
7783                                 cf_cv_shlib_version=rel
7784                         fi
7785                         fi
7786                         CF_SHARED_SONAME
7787                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
7788                 else
7789                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -o $[@]'
7790                 fi
7791                 ;;
7792         (osf*|mls+*)
7793                 # tested with OSF/1 V3.2 and 'cc'
7794                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
7795                 # link with shared libs).
7796                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
7797                 case "$host_os" in
7798                 (osf4*)
7799                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
7800                         ;;
7801                 esac
7802                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
7803                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7804                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7805                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7806                 fi
7807                 cf_cv_rm_so_locs=yes
7808                 ;;
7809         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
7810                 # tested with osr5.0.5
7811                 if test "$GCC" != yes; then
7812                         CC_SHARED_OPTS='-belf -KPIC'
7813                 fi
7814                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
7815                 if test "$cf_cv_enable_rpath" = yes ; then
7816                         # only way is to set LD_RUN_PATH but no switch for it
7817                         RUN_PATH=$libdir
7818                 fi
7819                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7820                 LINK_PROGS='LD_RUN_PATH=${libdir}'
7821                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
7822                 ;;
7823         (sunos4*)
7824                 # tested with SunOS 4.1.1 and gcc 2.7.0
7825                 if test "$GCC" != yes; then
7826                         CC_SHARED_OPTS='-KPIC'
7827                 fi
7828                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
7829                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7830                 ;;
7831         (solaris2*)
7832                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
7833                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
7834                 if test "$DFT_LWR_MODEL" = "shared" ; then
7835                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
7836                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7837                 fi
7838                 if test "$cf_cv_enable_rpath" = yes ; then
7839                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
7840                 fi
7841                 CF_SHARED_SONAME
7842                 if test "$GCC" != yes; then
7843                         cf_save_CFLAGS="$CFLAGS"
7844                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
7845                         do
7846                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
7847                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\\n");],[break])
7848                         done
7849                         CFLAGS="$cf_save_CFLAGS"
7850                         CC_SHARED_OPTS=$cf_shared_opts
7851                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
7852                 else
7853                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
7854                 fi
7855                 ;;
7856         (sysv5uw7*|unix_sv*)
7857                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
7858                 if test "$GCC" != yes; then
7859                         CC_SHARED_OPTS='-KPIC'
7860                 fi
7861                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
7862                 ;;
7863         (*)
7864                 CC_SHARED_OPTS='unknown'
7865                 MK_SHARED_LIB='echo unknown'
7866                 ;;
7867         esac
7868
7869         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
7870         case "$cf_cv_shlib_version" in
7871         (rel|abi)
7872                 case "$MK_SHARED_LIB" in
7873                 (*'-o $[@]')
7874                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
7875                         ;;
7876                 (*)
7877                         AC_MSG_WARN(ignored --with-shlib-version)
7878                         ;;
7879                 esac
7880                 ;;
7881         esac
7882
7883         if test -n "$cf_try_cflags"
7884         then
7885 cat > conftest.$ac_ext <<EOF
7886 #line __oline__ "${as_me:-configure}"
7887 #include <stdio.h>
7888 int main(int argc, char *argv[[]])
7889 {
7890         printf("hello\\n");
7891         return (argv[[argc-1]] == 0) ;
7892 }
7893 EOF
7894                 cf_save_CFLAGS="$CFLAGS"
7895                 for cf_opt in $cf_try_cflags
7896                 do
7897                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
7898                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
7899                         if AC_TRY_EVAL(ac_compile); then
7900                                 AC_MSG_RESULT(yes)
7901                                 cf_save_CFLAGS="$CFLAGS"
7902                         else
7903                                 AC_MSG_RESULT(no)
7904                         fi
7905                 done
7906                 CFLAGS="$cf_save_CFLAGS"
7907         fi
7908
7909
7910         # RPATH_LIST is a colon-separated list of directories
7911         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
7912         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
7913
7914         test "$cf_cv_rm_so_locs" = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
7915
7916         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
7917         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7918
7919         AC_SUBST(CC_SHARED_OPTS)
7920         AC_SUBST(LD_RPATH_OPT)
7921         AC_SUBST(LD_SHARED_OPTS)
7922         AC_SUBST(MK_SHARED_LIB)
7923         AC_SUBST(RM_SHARED_OPTS)
7924
7925         AC_SUBST(LINK_PROGS)
7926         AC_SUBST(LINK_TESTS)
7927
7928         AC_SUBST(EXTRA_LDFLAGS)
7929         AC_SUBST(LOCAL_LDFLAGS)
7930         AC_SUBST(LOCAL_LDFLAGS2)
7931
7932         AC_SUBST(INSTALL_LIB)
7933         AC_SUBST(RPATH_LIST)
7934 ])dnl
7935 dnl ---------------------------------------------------------------------------
7936 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
7937 dnl ----------------
7938 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
7939 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
7940 dnl option.
7941 dnl
7942 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
7943 dnl If missing, use "rel".
7944 define([CF_SHARED_SONAME],
7945 [
7946         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
7947         if test "$cf_cv_shlib_version" = rel; then
7948                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
7949         else
7950                 cf_cv_shared_soname='`basename $[@]`'
7951         fi
7952 ])
7953 dnl ---------------------------------------------------------------------------
7954 dnl CF_SIGWINCH version: 7 updated: 2023/02/18 17:41:25
7955 dnl -----------
7956 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
7957 dnl programs need this test).
7958 dnl
7959 dnl This is really a Mac OS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
7960 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
7961 dnl winsize declaration is left alone - we may revisit this if Apple choose to
7962 dnl break that part of the interface as well.
7963 AC_DEFUN([CF_SIGWINCH],
7964 [
7965 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
7966         AC_TRY_COMPILE([
7967 #include <sys/types.h>
7968 #include <sys/signal.h>
7969 ],[int x = SIGWINCH; (void)x],
7970         [cf_cv_define_sigwinch=yes],
7971         [AC_TRY_COMPILE([
7972 #undef _XOPEN_SOURCE
7973 #undef _POSIX_SOURCE
7974 #undef _POSIX_C_SOURCE
7975 #include <sys/types.h>
7976 #include <sys/signal.h>
7977 ],[int x = SIGWINCH; (void)x],
7978         [cf_cv_define_sigwinch=maybe],
7979         [cf_cv_define_sigwinch=no])
7980 ])
7981 ])
7982
7983 if test "$cf_cv_define_sigwinch" = maybe ; then
7984 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
7985 cf_cv_fixup_sigwinch=unknown
7986 cf_sigwinch=32
7987 while test "$cf_sigwinch" != 1
7988 do
7989         AC_TRY_COMPILE([
7990 #undef _XOPEN_SOURCE
7991 #undef _POSIX_SOURCE
7992 #undef _POSIX_C_SOURCE
7993 #include <sys/types.h>
7994 #include <sys/signal.h>
7995 ],[
7996 #if SIGWINCH != $cf_sigwinch
7997 #error SIGWINCH is not $cf_sigwinch
7998 #endif
7999 int x = SIGWINCH; (void)x],
8000         [cf_cv_fixup_sigwinch=$cf_sigwinch
8001          break])
8002
8003 cf_sigwinch="`expr "$cf_sigwinch" - 1`"
8004 done
8005 ])
8006
8007         if test "$cf_cv_fixup_sigwinch" != unknown ; then
8008                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
8009         fi
8010 fi
8011 ])dnl
8012 dnl ---------------------------------------------------------------------------
8013 dnl CF_SIG_ATOMIC_T version: 5 updated: 2020/03/10 18:53:47
8014 dnl ---------------
8015 dnl signal handler, but there are some gcc dependencies in that recommendation.
8016 dnl Try anyway.
8017 AC_DEFUN([CF_SIG_ATOMIC_T],
8018 [
8019 AC_MSG_CHECKING(for signal global datatype)
8020 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
8021         for cf_type in \
8022                 "volatile sig_atomic_t" \
8023                 "sig_atomic_t" \
8024                 "int"
8025         do
8026         AC_TRY_COMPILE([
8027 #include <sys/types.h>
8028 #include <signal.h>
8029 #include <stdio.h>
8030
8031 extern $cf_type x;
8032 $cf_type x;
8033 static void handler(int sig)
8034 {
8035         (void)sig;
8036         x = 5;
8037 }],
8038                 [signal(SIGINT, handler);
8039                  x = 1],
8040                 [cf_cv_sig_atomic_t=$cf_type],
8041                 [cf_cv_sig_atomic_t=no])
8042                 test "$cf_cv_sig_atomic_t" != no && break
8043         done
8044         ])
8045 AC_MSG_RESULT($cf_cv_sig_atomic_t)
8046 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
8047 ])dnl
8048 dnl ---------------------------------------------------------------------------
8049 dnl CF_SIZECHANGE version: 18 updated: 2021/09/04 06:35:04
8050 dnl -------------
8051 dnl Check for definitions & structures needed for window size-changing
8052 dnl
8053 dnl https://stackoverflow.com/questions/18878141/difference-between-structures-ttysize-and-winsize/50769952#50769952
8054 AC_DEFUN([CF_SIZECHANGE],
8055 [
8056 AC_REQUIRE([CF_STRUCT_TERMIOS])
8057 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
8058         cf_cv_sizechange=unknown
8059         cf_save_CPPFLAGS="$CPPFLAGS"
8060
8061 for cf_opts in "" "NEED_PTEM_H"
8062 do
8063
8064         CPPFLAGS="$cf_save_CPPFLAGS"
8065         if test -n "$cf_opts"
8066         then
8067                 CF_APPEND_TEXT(CPPFLAGS,-D$cf_opts)
8068         fi
8069         AC_TRY_COMPILE([#include <sys/types.h>
8070 #ifdef HAVE_TERMIOS_H
8071 #include <termios.h>
8072 #else
8073 #ifdef HAVE_TERMIO_H
8074 #include <termio.h>
8075 #endif
8076 #endif
8077
8078 #ifdef NEED_PTEM_H
8079 /* This is a workaround for SCO:  they neglected to define struct winsize in
8080  * termios.h -- it is only in termio.h and ptem.h
8081  */
8082 #include <sys/stream.h>
8083 #include <sys/ptem.h>
8084 #endif
8085
8086 #ifdef HAVE_SYS_IOCTL_H
8087 #include <sys/ioctl.h>
8088 #endif
8089 ],[
8090 #ifdef TIOCGSIZE
8091         struct ttysize win;     /* SunOS 3.0... */
8092         int y = win.ts_lines = 2;
8093         int x = win.ts_cols = 1;
8094         (void)y;
8095         (void)x;
8096 #else
8097 #ifdef TIOCGWINSZ
8098         struct winsize win;     /* everything else */
8099         int y = win.ws_row = 2;
8100         int x = win.ws_col = 1;
8101         (void)y;
8102         (void)x;
8103 #else
8104         no TIOCGSIZE or TIOCGWINSZ
8105 #endif /* TIOCGWINSZ */
8106 #endif /* TIOCGSIZE */
8107         ],
8108         [cf_cv_sizechange=yes],
8109         [cf_cv_sizechange=no])
8110
8111         CPPFLAGS="$cf_save_CPPFLAGS"
8112         if test "$cf_cv_sizechange" = yes ; then
8113                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
8114                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
8115                 break
8116         fi
8117 done
8118 ])
8119 if test "$cf_cv_sizechange" != no ; then
8120         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechange declarations are provided])
8121         case "$cf_cv_sizechange" in
8122         (NEED*)
8123                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
8124                 ;;
8125         esac
8126 fi
8127 ])dnl
8128 dnl ---------------------------------------------------------------------------
8129 dnl CF_SRC_MODULES version: 34 updated: 2023/04/22 11:51:06
8130 dnl --------------
8131 dnl For each parameter, test if the source-directory exists, and if it contains
8132 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
8133 dnl use in CF_LIB_RULES.
8134 dnl
8135 dnl This uses the configured value to make the lists SRC_SUBDIRS and
8136 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
8137 AC_DEFUN([CF_SRC_MODULES],
8138 [
8139 AC_REQUIRE([CF_CHECK_GNAT_VERSION])
8140 AC_MSG_CHECKING(for src modules)
8141
8142 # dependencies and linker-arguments for test-programs
8143 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
8144 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
8145 if test "$DFT_LWR_MODEL" = "libtool"; then
8146         TEST_ARGS="${TEST_DEPS}"
8147         TEST_ARG2="${TEST_DEP2}"
8148 else
8149         TEST_ARGS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
8150         TEST_ARG2="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARG2"
8151 fi
8152
8153 PC_MODULES_TO_MAKE="ncurses${USE_ARG_SUFFIX}"
8154 cf_cv_src_modules=
8155 for cf_dir in $1
8156 do
8157         if test -f "$srcdir/$cf_dir/modules" ; then
8158
8159                 if test -z "$cf_cv_src_modules"; then
8160                         cf_cv_src_modules=$cf_dir
8161                 else
8162                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
8163                 fi
8164
8165                 # Make the ncurses_cfg.h file record the library interface files as
8166                 # well.  These are header files that are the same name as their
8167                 # directory.  Ncurses is the only library that does not follow
8168                 # that pattern.
8169                 if test -f "$srcdir/${cf_dir}/${cf_dir}.h" ; then
8170                         CF_UPPER(cf_have_include,$cf_dir)
8171                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
8172                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
8173                         CF_MAP_LIB_BASENAME(TEST_ROOT,$cf_dir)
8174                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEPS"
8175                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEP2"
8176                         if test "$DFT_LWR_MODEL" = "libtool"; then
8177                                 TEST_ARGS="${TEST_DEPS}"
8178                                 TEST_ARG2="${TEST_DEP2}"
8179                         else
8180                                 TEST_ARGS="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARGS"
8181                                 TEST_ARG2="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARG2"
8182                         fi
8183                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${USE_ARG_SUFFIX}"
8184                 fi
8185         fi
8186 done
8187 AC_MSG_RESULT($cf_cv_src_modules)
8188
8189 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
8190 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
8191
8192 AC_SUBST(TEST_ARGS)
8193 AC_SUBST(TEST_DEPS)
8194
8195 AC_SUBST(TEST_ARG2)
8196 AC_SUBST(TEST_DEP2)
8197
8198 SRC_SUBDIRS=
8199 if test "x$cf_with_manpages" != xno ; then
8200         SRC_SUBDIRS="$SRC_SUBDIRS man"
8201 fi
8202 SRC_SUBDIRS="$SRC_SUBDIRS include"
8203 for cf_dir in $cf_cv_src_modules
8204 do
8205         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
8206 done
8207 if test "x$cf_with_tests" != "xno" ; then
8208         SRC_SUBDIRS="$SRC_SUBDIRS test"
8209 fi
8210 # always make this, to install the ncurses-config script
8211 SRC_SUBDIRS="$SRC_SUBDIRS misc"
8212 if test "$cf_with_cxx_binding" != no; then
8213         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${USE_ARG_SUFFIX}"
8214         SRC_SUBDIRS="$SRC_SUBDIRS c++"
8215 fi
8216
8217 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
8218 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
8219
8220 AC_SUBST(PC_MODULES_TO_MAKE)
8221
8222 ADA_SUBDIRS=
8223 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f "$srcdir/Ada95/Makefile.in" ; then
8224         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
8225         ADA_SUBDIRS="gen src"
8226         if test "x$cf_with_tests" != "xno" ; then
8227                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
8228         fi
8229 fi
8230
8231 SUB_MAKEFILES=
8232 for cf_dir in $SRC_SUBDIRS
8233 do
8234         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
8235 done
8236
8237 if test -n "$ADA_SUBDIRS"; then
8238         for cf_dir in $ADA_SUBDIRS
8239         do
8240                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
8241         done
8242         AC_SUBST(ADA_SUBDIRS)
8243 fi
8244 ])dnl
8245 dnl ---------------------------------------------------------------------------
8246 dnl CF_STDCPP_LIBRARY version: 12 updated: 2021/01/01 13:31:04
8247 dnl -----------------
8248 dnl Check for -lstdc++, which is GNU's standard C++ library.
8249 dnl If $CXXLIBS is set, add that to the libraries used for test-linking.
8250 dnl If -lstdc++ was not already added to $LIBS or $CXXLIBS, and is needed,
8251 dnl add it to $CXXLIBS.
8252 AC_DEFUN([CF_STDCPP_LIBRARY],
8253 [
8254 if test -n "$GXX" ; then
8255
8256         cf_save="$LIBS"
8257         LIBS="$LIBS $CXXLIBS"
8258         AC_MSG_CHECKING(if we already have C++ library)
8259         AC_TRY_LINK([
8260                         #include <iostream>],[
8261                         std::cout << "Hello World!" << std::endl;],
8262                 [cf_have_libstdcpp=yes],
8263                 [cf_have_libstdcpp=no])
8264         AC_MSG_RESULT($cf_have_libstdcpp)
8265         LIBS="$cf_save"
8266
8267         if test "$cf_have_libstdcpp" != yes
8268         then
8269                 case "$cf_cv_system_name" in
8270                 (os2*)
8271                         if test -z "`g++ -dM -E - < /dev/null | grep __KLIBC__`"; then
8272                                 cf_stdcpp_libname=stdcpp
8273                         else
8274                                 cf_stdcpp_libname=stdc++
8275                         fi
8276                         ;;
8277                 (*)
8278                         cf_stdcpp_libname=stdc++
8279                         ;;
8280                 esac
8281
8282                 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
8283                         cf_save="$LIBS"
8284                         LIBS="$LIBS $CXXLIBS"
8285                         CF_ADD_LIB($cf_stdcpp_libname)
8286                 AC_TRY_LINK([
8287                                 #include <iostream>],[
8288                                 std::cout << "Hello World!" << std::endl;],
8289                         [cf_cv_libstdcpp=yes],
8290                         [cf_cv_libstdcpp=no])
8291                         LIBS="$cf_save"
8292                 ])
8293                 test "$cf_cv_libstdcpp" = yes && { CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS) }
8294         fi
8295 fi
8296 ])dnl
8297 dnl ---------------------------------------------------------------------------
8298 dnl CF_STRIP_G_OPT version: 4 updated: 2021/01/02 09:31:20
8299 dnl --------------
8300 dnl     Remove "-g" option from the compiler options
8301 AC_DEFUN([CF_STRIP_G_OPT],
8302 [$1=`echo "${$1}" | CF__SED_TRIMBLANKS(-e 's%-g %%' -e 's%-g$%%')`])dnl
8303 dnl ---------------------------------------------------------------------------
8304 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
8305 dnl -------------------
8306 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
8307 dnl do this if we've found the sigaction function.
8308 AC_DEFUN([CF_STRUCT_SIGACTION],[
8309 AC_REQUIRE([CF_XOPEN_SOURCE])
8310
8311 if test "$ac_cv_func_sigaction" = yes; then
8312 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
8313 AC_TRY_COMPILE([
8314 #include <sys/types.h>
8315 #include <signal.h>],
8316         [struct sigaction act],
8317         [sigact_bad=no],
8318         [
8319 AC_TRY_COMPILE([
8320 #define _POSIX_SOURCE
8321 #include <sys/types.h>
8322 #include <signal.h>],
8323         [struct sigaction act],
8324         [sigact_bad=yes
8325          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
8326          [sigact_bad=unknown])])
8327 AC_MSG_RESULT($sigact_bad)
8328 fi
8329 ])dnl
8330 dnl ---------------------------------------------------------------------------
8331 dnl CF_STRUCT_TERMIOS version: 11 updated: 2020/03/19 20:46:13
8332 dnl -----------------
8333 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
8334 AC_DEFUN([CF_STRUCT_TERMIOS],[
8335 AC_REQUIRE([CF_XOPEN_SOURCE])
8336
8337 AC_CHECK_HEADERS( \
8338 termio.h \
8339 termios.h \
8340 unistd.h \
8341 sys/ioctl.h \
8342 sys/termio.h \
8343 )
8344
8345 if test "$ac_cv_header_termios_h" = yes ; then
8346         case "$CFLAGS $CPPFLAGS" in
8347         (*-D_POSIX_SOURCE*)
8348                 termios_bad=dunno ;;
8349         (*)     termios_bad=maybe ;;
8350         esac
8351         if test "$termios_bad" = maybe ; then
8352         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
8353         AC_TRY_COMPILE([#include <termios.h>],
8354                 [struct termios foo; int x = foo.c_iflag = 1; (void)x],
8355                 termios_bad=no, [
8356                 AC_TRY_COMPILE([
8357 #define _POSIX_SOURCE
8358 #include <termios.h>],
8359                         [struct termios foo; int x = foo.c_iflag = 2; (void)x],
8360                         termios_bad=unknown,
8361                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
8362                         ])
8363         AC_MSG_RESULT($termios_bad)
8364         fi
8365 fi
8366 ])dnl
8367 dnl ---------------------------------------------------------------------------
8368 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
8369 dnl --------------
8370 dnl Construct a search-list for a nonstandard header/lib-file
8371 dnl     $1 = the variable to return as result
8372 dnl     $2 = the package name
8373 dnl     $3 = the subdirectory, e.g., bin, include or lib
8374 AC_DEFUN([CF_SUBDIR_PATH],
8375 [
8376 $1=
8377
8378 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
8379
8380 for cf_subdir_prefix in \
8381         /usr \
8382         /usr/local \
8383         /usr/pkg \
8384         /opt \
8385         /opt/local \
8386         [$]HOME
8387 do
8388         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
8389 done
8390 ])dnl
8391 dnl ---------------------------------------------------------------------------
8392 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
8393 dnl -----------
8394 dnl     Shorthand macro for substituting things that the user may override
8395 dnl     with an environment variable.
8396 dnl
8397 dnl     $1 = condition to pass to "test"
8398 dnl     $2 = environment variable
8399 dnl     $3 = value if the test succeeds
8400 dnl     $4 = value if the test fails
8401 AC_DEFUN([CF_SUBST_IF],
8402 [
8403 if test $1 ; then
8404         $2=$3
8405 ifelse($4,,,[else
8406         $2=$4])
8407 fi
8408 AC_SUBST($2)
8409 ])dnl
8410 dnl ---------------------------------------------------------------------------
8411 dnl CF_SUBST_NCURSES_VERSION version: 11 updated: 2023/01/07 16:32:06
8412 dnl ------------------------
8413 dnl Get the version-number for use in shared-library naming, etc.
8414 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
8415 [AC_REQUIRE([AC_PROG_EGREP])dnl
8416
8417 NCURSES_MAJOR="`${EGREP-egrep} '^NCURSES_MAJOR[[        ]]*=' "$srcdir/dist.mk" | sed -e 's/^[[^0-9]]*//'`"
8418 NCURSES_MINOR="`${EGREP-egrep} '^NCURSES_MINOR[[        ]]*=' "$srcdir/dist.mk" | sed -e 's/^[[^0-9]]*//'`"
8419 NCURSES_PATCH="`${EGREP-egrep} '^NCURSES_PATCH[[        ]]*=' "$srcdir/dist.mk" | sed -e 's/^[[^0-9]]*//'`"
8420 cf_cv_abi_version=${NCURSES_MAJOR}
8421 cf_cv_abi_default=${NCURSES_MAJOR}
8422 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
8423 dnl Show the computed version, for logging
8424 cf_cv_timestamp=`date`
8425 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_default ($cf_cv_timestamp))
8426 dnl We need these values in the generated headers
8427 AC_SUBST(NCURSES_MAJOR)
8428 AC_SUBST(NCURSES_MINOR)
8429 AC_SUBST(NCURSES_PATCH)
8430 dnl We need these values in the generated makefiles
8431 AC_SUBST(cf_cv_rel_version)
8432 AC_SUBST(cf_cv_abi_version)
8433 AC_SUBST(cf_cv_abi_default)
8434 AC_SUBST(cf_cv_builtin_bool)
8435 AC_SUBST(cf_cv_header_stdbool_h)
8436 AC_SUBST(cf_cv_type_of_bool)dnl
8437 ])dnl
8438 dnl ---------------------------------------------------------------------------
8439 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
8440 dnl ------------------
8441 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
8442 dnl older SCO configurations.
8443 AC_DEFUN([CF_SYS_TIME_SELECT],
8444 [
8445 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
8446 AC_CACHE_VAL(cf_cv_sys_time_select,[
8447 AC_TRY_COMPILE([
8448 #include <sys/types.h>
8449 #ifdef HAVE_SYS_TIME_H
8450 #include <sys/time.h>
8451 #endif
8452 #ifdef HAVE_SYS_SELECT_H
8453 #include <sys/select.h>
8454 #endif
8455 ],[],[cf_cv_sys_time_select=yes],
8456          [cf_cv_sys_time_select=no])
8457          ])
8458 AC_MSG_RESULT($cf_cv_sys_time_select)
8459 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
8460 ])dnl
8461 dnl ---------------------------------------------------------------------------
8462 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
8463 dnl ---------------
8464 dnl Define a top_builddir symbol, for applications that need an absolute path.
8465 AC_DEFUN([CF_TOP_BUILDDIR],
8466 [
8467 top_builddir=ifelse($1,,`pwd`,$1)
8468 AC_SUBST(top_builddir)
8469 ])dnl
8470 dnl ---------------------------------------------------------------------------
8471 dnl CF_TRY_PKG_CONFIG version: 6 updated: 2020/12/31 10:54:15
8472 dnl -----------------
8473 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
8474 dnl available in that form.
8475 dnl
8476 dnl $1 = package name, which may be a shell variable
8477 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
8478 dnl $3 = logic to use if pkg-config does not have the package
8479 AC_DEFUN([CF_TRY_PKG_CONFIG],[
8480 AC_REQUIRE([CF_PKG_CONFIG])
8481
8482 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists "$1"; then
8483         CF_VERBOSE(found package $1)
8484         cf_pkgconfig_incs="`$PKG_CONFIG --cflags "$1" 2>/dev/null`"
8485         cf_pkgconfig_libs="`$PKG_CONFIG --libs   "$1" 2>/dev/null`"
8486         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
8487         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
8488         CF_ADD_CFLAGS($cf_pkgconfig_incs)
8489         CF_ADD_LIBS($cf_pkgconfig_libs)
8490         ifelse([$2],,:,[$2])
8491 else
8492         cf_pkgconfig_incs=
8493         cf_pkgconfig_libs=
8494         ifelse([$3],,:,[$3])
8495 fi
8496 ])
8497 dnl ---------------------------------------------------------------------------
8498 dnl CF_TRY_XOPEN_SOURCE version: 4 updated: 2022/09/10 15:16:16
8499 dnl -------------------
8500 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
8501 dnl can define it successfully.
8502 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
8503 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
8504         AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,
8505         [cf_cv_xopen_source=no],
8506         [cf_save="$CPPFLAGS"
8507          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
8508          AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,
8509                 [cf_cv_xopen_source=no],
8510                 [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
8511                 CPPFLAGS="$cf_save"
8512         ])
8513 ])
8514
8515 if test "$cf_cv_xopen_source" != no ; then
8516         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
8517         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
8518         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
8519         CF_APPEND_CFLAGS($cf_temp_xopen_source)
8520 fi
8521 ])
8522 dnl ---------------------------------------------------------------------------
8523 dnl CF_TYPEOF_CHTYPE version: 11 updated: 2023/01/05 17:57:59
8524 dnl ----------------
8525 dnl Determine the type we should use for chtype (and attr_t, which is treated
8526 dnl as the same thing).  We want around 32 bits, so on most machines want a
8527 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
8528 dnl wide characters, we have to have a type compatible with that, as well.
8529 AC_DEFUN([CF_TYPEOF_CHTYPE],
8530 [
8531 AC_MSG_CHECKING([for type of chtype])
8532 AC_CACHE_VAL(cf_cv_typeof_chtype,[
8533                 AC_TRY_RUN([
8534 $ac_includes_default
8535 #define WANT_BITS 31
8536 int main(void)
8537 {
8538         FILE *fp = fopen("cf_test.out", "w");
8539         if (fp != 0) {
8540                 char *result = "long";
8541                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
8542                         int n;
8543                         unsigned int x, y;
8544                         for (n = 0; n < WANT_BITS; n++) {
8545                                 x = (1 << n);
8546                                 y = (x >> n);
8547                                 if (y != 1 || x == 0) {
8548                                         x = 0;
8549                                         break;
8550                                 }
8551                         }
8552                         /*
8553                          * If x is nonzero, an int is big enough for the bits
8554                          * that we want.
8555                          */
8556                         result = (x != 0) ? "int" : "long";
8557                 }
8558                 fputs(result, fp);
8559                 fclose(fp);
8560         }
8561         ${cf_cv_main_return:-return}(0);
8562 }
8563                 ],
8564                 [cf_cv_typeof_chtype=`cat cf_test.out`],
8565                 [cf_cv_typeof_chtype=long],
8566                 [cf_cv_typeof_chtype=long])
8567                 rm -f cf_test.out
8568         ])
8569 AC_MSG_RESULT($cf_cv_typeof_chtype)
8570
8571 AC_SUBST(cf_cv_typeof_chtype)
8572 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
8573 ])dnl
8574 dnl ---------------------------------------------------------------------------
8575 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
8576 dnl -----------------
8577 dnl
8578 AC_DEFUN([CF_TYPE_SIGACTION],
8579 [
8580 AC_MSG_CHECKING([for type sigaction_t])
8581 AC_CACHE_VAL(cf_cv_type_sigaction,[
8582         AC_TRY_COMPILE([
8583 #include <signal.h>],
8584                 [sigaction_t x],
8585                 [cf_cv_type_sigaction=yes],
8586                 [cf_cv_type_sigaction=no])])
8587 AC_MSG_RESULT($cf_cv_type_sigaction)
8588 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
8589 ])dnl
8590 dnl ---------------------------------------------------------------------------
8591 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
8592 dnl --------------------
8593 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
8594 dnl won't, but they're still there.
8595 AC_DEFUN([CF_UNSIGNED_LITERALS],
8596 [
8597 AC_MSG_CHECKING([if unsigned literals are legal])
8598 AC_CACHE_VAL(cf_cv_unsigned_literals,[
8599         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
8600                 [cf_cv_unsigned_literals=yes],
8601                 [cf_cv_unsigned_literals=no])
8602         ])
8603 AC_MSG_RESULT($cf_cv_unsigned_literals)
8604 ])dnl
8605 dnl ---------------------------------------------------------------------------
8606 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
8607 dnl --------
8608 dnl Make an uppercase version of a variable
8609 dnl $1=uppercase($2)
8610 AC_DEFUN([CF_UPPER],
8611 [
8612 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
8613 ])dnl
8614 dnl ---------------------------------------------------------------------------
8615 dnl CF_UTF8_LIB version: 10 updated: 2023/01/11 04:05:23
8616 dnl -----------
8617 dnl Check for multibyte support, and if not found, utf8 compatibility library
8618 AC_DEFUN([CF_UTF8_LIB],
8619 [
8620 AC_HAVE_HEADERS(wchar.h)
8621 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
8622         cf_save_LIBS="$LIBS"
8623         AC_TRY_LINK([
8624 $ac_includes_default
8625 #ifdef HAVE_WCHAR_H
8626 #include <wchar.h>
8627 #endif
8628 ],[putwc(0,0);],
8629         [cf_cv_utf8_lib=yes],
8630         [CF_FIND_LINKAGE([
8631 #include <libutf8.h>],[putwc(0,0);],utf8,
8632                 [cf_cv_utf8_lib=add-on],
8633                 [cf_cv_utf8_lib=no])
8634 ])])
8635
8636 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
8637 # ncurses/ncursesw:
8638 if test "$cf_cv_utf8_lib" = "add-on" ; then
8639         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
8640         CF_ADD_INCDIR($cf_cv_header_path_utf8)
8641         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
8642         CF_ADD_LIBS($cf_cv_library_file_utf8)
8643 fi
8644 ])dnl
8645 dnl ---------------------------------------------------------------------------
8646 dnl CF_VA_COPY version: 6 updated: 2018/12/04 18:14:25
8647 dnl ----------
8648 dnl check for va_copy, part of stdarg.h starting with ISO C 1999.
8649 dnl Also, workaround for glibc's __va_copy, by checking for both.
8650 dnl Finally, try to accommodate pre-ISO C 1999 headers.
8651 AC_DEFUN([CF_VA_COPY],[
8652 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
8653 AC_TRY_LINK([
8654 #include <stdarg.h>
8655 ],[
8656         static va_list dst;
8657         static va_list src;
8658         va_copy(dst, src)],
8659         cf_cv_have_va_copy=yes,
8660         cf_cv_have_va_copy=no)])
8661
8662 if test "$cf_cv_have_va_copy" = yes;
8663 then
8664         AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
8665 else # !cf_cv_have_va_copy
8666
8667 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
8668 AC_TRY_LINK([
8669 #include <stdarg.h>
8670 ],[
8671         static va_list dst;
8672         static va_list src;
8673         __va_copy(dst, src)],
8674         cf_cv_have___va_copy=yes,
8675         cf_cv_have___va_copy=no)])
8676
8677 if test "$cf_cv_have___va_copy" = yes
8678 then
8679         AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
8680 else # !cf_cv_have___va_copy
8681
8682 AC_CACHE_CHECK(for __builtin_va_copy, cf_cv_have___builtin_va_copy,[
8683 AC_TRY_LINK([
8684 #include <stdarg.h>
8685 ],[
8686         static va_list dst;
8687         static va_list src;
8688         __builtin_va_copy(dst, src)],
8689         cf_cv_have___builtin_va_copy=yes,
8690         cf_cv_have___builtin_va_copy=no)])
8691
8692 test "$cf_cv_have___builtin_va_copy" = yes &&
8693         AC_DEFINE(HAVE___BUILTIN_VA_COPY,1,[Define to 1 if we have __builtin_va_copy])
8694
8695 fi # cf_cv_have___va_copy
8696
8697 fi # cf_cv_have_va_copy
8698
8699 case "${cf_cv_have_va_copy}${cf_cv_have___va_copy}${cf_cv_have___builtin_va_copy}" in
8700 (*yes*)
8701         ;;
8702
8703 (*)
8704         AC_CACHE_CHECK(if we can simply copy va_list, cf_cv_pointer_va_list,[
8705 AC_TRY_LINK([
8706 #include <stdarg.h>
8707 ],[
8708         va_list dst;
8709         va_list src;
8710         dst = src],
8711         cf_cv_pointer_va_list=yes,
8712         cf_cv_pointer_va_list=no)])
8713
8714         if test "$cf_cv_pointer_va_list" = no
8715         then
8716                 AC_CACHE_CHECK(if we can copy va_list indirectly, cf_cv_array_va_list,[
8717 AC_TRY_LINK([
8718 #include <stdarg.h>
8719 ],[
8720         va_list dst;
8721         va_list src;
8722         *dst = *src],
8723                         cf_cv_array_va_list=yes,
8724                         cf_cv_array_va_list=no)])
8725                 test "$cf_cv_array_va_list" = yes && AC_DEFINE(ARRAY_VA_LIST,1,[Define to 1 if we can copy va_list indirectly])
8726         fi
8727         ;;
8728 esac
8729 ])
8730 dnl ---------------------------------------------------------------------------
8731 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
8732 dnl ----------
8733 dnl Use AC_VERBOSE w/o the warnings
8734 AC_DEFUN([CF_VERBOSE],
8735 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
8736 CF_MSG_LOG([$1])
8737 ])dnl
8738 dnl ---------------------------------------------------------------------------
8739 dnl CF_VERSION_INFO version: 8 updated: 2021/01/01 13:31:04
8740 dnl ---------------
8741 dnl Define several useful symbols derived from the VERSION file.  A separate
8742 dnl file is preferred to embedding the version numbers in various scripts.
8743 dnl (automake is a textbook-example of why the latter is a bad idea, but there
8744 dnl are others).
8745 dnl
8746 dnl The file contents are:
8747 dnl     libtool-version release-version patch-version
8748 dnl or
8749 dnl     release-version
8750 dnl where
8751 dnl     libtool-version (see ?) consists of 3 integers separated by '.'
8752 dnl     release-version consists of a major version and minor version
8753 dnl             separated by '.', optionally followed by a patch-version
8754 dnl             separated by '-'.  The minor version need not be an
8755 dnl             integer (but it is preferred).
8756 dnl     patch-version is an integer in the form yyyymmdd, so ifdef's and
8757 dnl             scripts can easily compare versions.
8758 dnl
8759 dnl If libtool is used, the first form is required, since CF_WITH_LIBTOOL
8760 dnl simply extracts the first field using 'cut -f1'.
8761 dnl
8762 dnl Optional parameters:
8763 dnl $1 = internal name for package
8764 dnl $2 = external name for package
8765 AC_DEFUN([CF_VERSION_INFO],
8766 [
8767 if test -f "$srcdir/VERSION" ; then
8768         AC_MSG_CHECKING(for package version)
8769
8770         # if there are not enough fields, cut returns the last one...
8771         cf_field1=`sed -e '2,$d' "$srcdir/VERSION" |cut -f1`
8772         cf_field2=`sed -e '2,$d' "$srcdir/VERSION" |cut -f2`
8773         cf_field3=`sed -e '2,$d' "$srcdir/VERSION" |cut -f3`
8774
8775         # this is how CF_BUNDLED_INTL uses $VERSION:
8776         VERSION="$cf_field1"
8777
8778         VERSION_MAJOR=`echo "$cf_field2" | sed -e 's/\..*//'`
8779         test -z "$VERSION_MAJOR" && AC_MSG_ERROR(missing major-version)
8780
8781         VERSION_MINOR=`echo "$cf_field2" | sed -e 's/^[[^.]]*\.//' -e 's/-.*//'`
8782         test -z "$VERSION_MINOR" && AC_MSG_ERROR(missing minor-version)
8783
8784         AC_MSG_RESULT(${VERSION_MAJOR}.${VERSION_MINOR})
8785
8786         AC_MSG_CHECKING(for package patch date)
8787         VERSION_PATCH=`echo "$cf_field3" | sed -e 's/^[[^-]]*-//'`
8788         case .$VERSION_PATCH in
8789         (.)
8790                 AC_MSG_ERROR(missing patch-date $VERSION_PATCH)
8791                 ;;
8792         (.[[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]])
8793                 ;;
8794         (*)
8795                 AC_MSG_ERROR(illegal patch-date $VERSION_PATCH)
8796                 ;;
8797         esac
8798         AC_MSG_RESULT($VERSION_PATCH)
8799 else
8800         AC_MSG_ERROR(did not find $srcdir/VERSION)
8801 fi
8802
8803 # show the actual data that we have for versions:
8804 CF_VERBOSE(ABI VERSION $VERSION)
8805 CF_VERBOSE(VERSION_MAJOR $VERSION_MAJOR)
8806 CF_VERBOSE(VERSION_MINOR $VERSION_MINOR)
8807 CF_VERBOSE(VERSION_PATCH $VERSION_PATCH)
8808
8809 AC_SUBST(VERSION)
8810 AC_SUBST(VERSION_MAJOR)
8811 AC_SUBST(VERSION_MINOR)
8812 AC_SUBST(VERSION_PATCH)
8813
8814 dnl if a package name is given, define its corresponding version info.  We
8815 dnl need the package name to ensure that the defined symbols are unique.
8816 ifelse($1,,,[
8817         cf_PACKAGE=$1
8818         PACKAGE=ifelse($2,,$1,$2)
8819         AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",[Define to the package-name])
8820         AC_SUBST(PACKAGE)
8821         CF_UPPER(cf_PACKAGE,$cf_PACKAGE)
8822         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_VERSION,"${VERSION_MAJOR}.${VERSION_MINOR}")
8823         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_PATCHDATE,${VERSION_PATCH})
8824 ])
8825 ])dnl
8826 dnl ---------------------------------------------------------------------------
8827 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
8828 dnl -------------
8829 dnl Check if type wide-character type $1 is declared, and if so, which header
8830 dnl file is needed.  The second parameter is used to set a shell variable when
8831 dnl the type is not found.  The first parameter sets a shell variable for the
8832 dnl opposite sense.
8833 AC_DEFUN([CF_WCHAR_TYPE],
8834 [
8835 # This is needed on Tru64 5.0 to declare $1
8836 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
8837 AC_TRY_COMPILE([
8838 #include <stdlib.h>
8839 #include <stdarg.h>
8840 #include <stdio.h>
8841 #ifdef HAVE_LIBUTF8_H
8842 #include <libutf8.h>
8843 #endif],
8844         [$1 state],
8845         [cf_cv_$1=no],
8846         [AC_TRY_COMPILE([
8847 #include <stdlib.h>
8848 #include <stdarg.h>
8849 #include <stdio.h>
8850 #include <wchar.h>
8851 #ifdef HAVE_LIBUTF8_H
8852 #include <libutf8.h>
8853 #endif],
8854         [$1 value],
8855         [cf_cv_$1=yes],
8856         [cf_cv_$1=unknown])])])
8857
8858 if test "$cf_cv_$1" = yes ; then
8859         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
8860         NEED_WCHAR_H=1
8861 fi
8862
8863 ifelse([$2],,,[
8864 # if we do not find $1 in either place, use substitution to provide a fallback.
8865 if test "$cf_cv_$1" = unknown ; then
8866         $2=1
8867 fi
8868 ])
8869 ifelse($3,,,[
8870 # if we find $1 in either place, use substitution to provide a fallback.
8871 if test "$cf_cv_$1" != unknown ; then
8872         $3=1
8873 fi
8874 ])
8875 ])dnl
8876 dnl ---------------------------------------------------------------------------
8877 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
8878 dnl ---------------
8879 dnl Check for compiler-support for weak symbols.
8880 dnl This works with "recent" gcc.
8881 AC_DEFUN([CF_WEAK_SYMBOLS],[
8882 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
8883
8884 AC_TRY_COMPILE([
8885 #include <stdio.h>],
8886 [
8887 #if defined(__GNUC__)
8888 #  if defined __USE_ISOC99
8889 #    define _cat_pragma(exp)    _Pragma(#exp)
8890 #    define _weak_pragma(exp)   _cat_pragma(weak name)
8891 #  else
8892 #    define _weak_pragma(exp)
8893 #  endif
8894 #  define _declare(name)        __extension__ extern __typeof__(name) name
8895 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
8896 #endif
8897
8898 weak_symbol(fopen);
8899 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
8900 ])
8901 ])dnl
8902 dnl ---------------------------------------------------------------------------
8903 dnl CF_WITH_ABI_ALTERED version: 1 updated: 2023/01/07 16:32:06
8904 dnl -------------------
8905 dnl Provide a way to override the displayed ABI version, e.g., in filenames.
8906 dnl Check this option after using the ABI version in configuration decisions.
8907 AC_DEFUN([CF_WITH_ABI_ALTERED],[
8908 AC_REQUIRE([CF_WITH_ABI_VERSION])
8909 AC_REQUIRE([CF_ABI_DEFAULTS])
8910 AC_ARG_WITH(abi-altered,
8911 [  --with-abi-altered=XXX  override visible ABI version, for packaging],[
8912         CF_NUMBER_SYNTAX($withval,ABI altered)
8913         if test "$cf_cv_abi_version" != "$withval"
8914         then
8915                 AC_MSG_WARN(altering visible ABI from $cf_cv_abi_version to $withval)
8916                 cf_cv_abi_version=$withval
8917         fi
8918 ])dnl
8919 ])dnl
8920 dnl ---------------------------------------------------------------------------
8921 dnl CF_WITH_ABI_VERSION version: 5 updated: 2023/01/07 16:32:06
8922 dnl -------------------
8923 dnl Allow library's ABI to be overridden.  Generally this happens when a
8924 dnl packager has incremented the ABI past that used in the original package,
8925 dnl and wishes to keep doing this.
8926 dnl
8927 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
8928 dnl symbol.
8929 AC_DEFUN([CF_WITH_ABI_VERSION],[
8930 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
8931 AC_ARG_WITH(abi-version,
8932 [  --with-abi-version=XXX  override derived ABI version],[
8933         if test "x$cf_cv_abi_version" != "x$withval"
8934         then
8935                 AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
8936                 case "$cf_cv_rel_version" in
8937                 (5.*)
8938                         cf_cv_rel_version=$withval.0
8939                         ;;
8940                 (6.*)
8941                         cf_cv_rel_version=$withval.9    # FIXME: should be 10 as of 6.0 release
8942                         ;;
8943                 esac
8944         fi
8945         cf_cv_abi_version=$withval])
8946         CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
8947 ifelse($1,,,[
8948 $1_ABI=$cf_cv_abi_version
8949 ])
8950 cf_cv_abi_default=$cf_cv_abi_version
8951 ])dnl
8952 dnl ---------------------------------------------------------------------------
8953 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
8954 dnl --------------------
8955 dnl Command-line option to specify the Ada95 compiler.
8956 AC_DEFUN([CF_WITH_ADA_COMPILER],[
8957 AC_MSG_CHECKING(for ada-compiler)
8958 AC_ARG_WITH(ada-compiler,
8959         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
8960         [cf_ada_compiler=$withval],
8961         [cf_ada_compiler=gnatmake])
8962 AC_SUBST(cf_ada_compiler)
8963 AC_MSG_RESULT($cf_ada_compiler)
8964 ])dnl
8965 dnl ---------------------------------------------------------------------------
8966 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
8967 dnl -------------------
8968 dnl Command-line option to specify where Ada includes will install.
8969 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
8970 AC_MSG_CHECKING(for ada-include)
8971 CF_WITH_PATH(ada-include,
8972    [  --with-ada-include=DIR  Ada includes are in DIR],
8973    ADA_INCLUDE,
8974    PREFIX/share/ada/adainclude,
8975    [$]prefix/share/ada/adainclude)
8976 AC_SUBST(ADA_INCLUDE)
8977 AC_MSG_RESULT($ADA_INCLUDE)
8978 ])dnl
8979 dnl ---------------------------------------------------------------------------
8980 dnl CF_WITH_ADA_LIBNAME version: 1 updated: 2019/09/07 18:59:41
8981 dnl -------------------
8982 dnl CF_WITH_ADA_LIBNAME
8983 dnl -------------------
8984 dnl Command-line option to specify how to name the resulting Ada library.
8985 dnl $1 = default value
8986 AC_DEFUN([CF_WITH_ADA_LIBNAME],[
8987 AC_MSG_CHECKING(for ada-libname)
8988 AC_ARG_WITH(ada-libname,
8989    [  --with-ada-libname=XXX  override default Ada library-name],
8990    ADA_LIBNAME=[$]withval,
8991    ADA_LIBNAME=$1)
8992 case "x$ADA_LIBNAME" in
8993 (x|xyes|xno)
8994         ADA_LIBNAME=$1
8995         ;;
8996 esac
8997 AC_SUBST(ADA_LIBNAME)
8998 AC_MSG_RESULT($ADA_LIBNAME)
8999 ])dnl
9000 dnl ---------------------------------------------------------------------------
9001 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
9002 dnl -------------------
9003 dnl Command-line option to specify where Ada objects will install.
9004 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
9005 AC_MSG_CHECKING(for ada-objects)
9006 CF_WITH_PATH(ada-objects,
9007    [  --with-ada-objects=DIR  Ada objects are in DIR],
9008    ADA_OBJECTS,
9009    PREFIX/lib/ada/adalib,
9010    [$]prefix/lib/ada/adalib)
9011 AC_SUBST(ADA_OBJECTS)
9012 AC_MSG_RESULT($ADA_OBJECTS)
9013 ])dnl
9014 dnl ---------------------------------------------------------------------------
9015 dnl CF_WITH_ADA_SHAREDLIB version: 5 updated: 2018/07/21 19:10:35
9016 dnl ---------------------
9017 dnl Command-line option to specify if an Ada95 shared-library should be built,
9018 dnl and optionally what its soname should be.
9019 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
9020 AC_REQUIRE([CF_GNAT_PROJECTS])
9021 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
9022 AC_ARG_WITH(ada-sharedlib,
9023         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
9024         [with_ada_sharedlib=$withval],
9025         [with_ada_sharedlib=no])
9026 AC_MSG_RESULT($with_ada_sharedlib)
9027
9028 if test "x$with_ada_sharedlib" != xno
9029 then
9030         if test "x$cf_gnat_projects" != xyes
9031         then
9032                 AC_MSG_WARN(disabling shared-library since GNAT projects are not supported)
9033                 with_ada_sharedlib=no
9034         fi
9035 fi
9036
9037 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
9038 MAKE_ADA_SHAREDLIB="#"
9039
9040 if test "x$with_ada_sharedlib" != xno
9041 then
9042         MAKE_ADA_SHAREDLIB=
9043         if test "x$with_ada_sharedlib" != xyes
9044         then
9045                 ADA_SHAREDLIB="$with_ada_sharedlib"
9046         fi
9047 fi
9048
9049 AC_SUBST(ADA_SHAREDLIB)
9050 AC_SUBST(MAKE_ADA_SHAREDLIB)
9051 ])dnl
9052 dnl ---------------------------------------------------------------------------
9053 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
9054 dnl ----------------
9055 dnl Configure-option for dbmalloc.  The optional parameter is used to override
9056 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
9057 AC_DEFUN([CF_WITH_DBMALLOC],[
9058 CF_NO_LEAKS_OPTION(dbmalloc,
9059         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
9060         [USE_DBMALLOC])
9061
9062 if test "$with_dbmalloc" = yes ; then
9063         AC_CHECK_HEADER(dbmalloc.h,
9064                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
9065 fi
9066 ])dnl
9067 dnl ---------------------------------------------------------------------------
9068 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
9069 dnl ---------------
9070 dnl Configure-option for dmalloc.  The optional parameter is used to override
9071 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
9072 AC_DEFUN([CF_WITH_DMALLOC],[
9073 CF_NO_LEAKS_OPTION(dmalloc,
9074         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
9075         [USE_DMALLOC])
9076
9077 if test "$with_dmalloc" = yes ; then
9078         AC_CHECK_HEADER(dmalloc.h,
9079                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
9080 fi
9081 ])dnl
9082 dnl ---------------------------------------------------------------------------
9083 dnl CF_WITH_EXPORT_SYMS version: 3 updated: 2014/12/20 19:16:08
9084 dnl -------------------
9085 dnl Use this with libtool to specify the list of symbols that may be exported.
9086 dnl The input file contains one symbol per line; comments work with "#".
9087 dnl
9088 dnl $1 = basename of the ".sym" file (default $PACKAGE)
9089 AC_DEFUN([CF_WITH_EXPORT_SYMS],
9090 [
9091 AC_MSG_CHECKING(if exported-symbols file should be used)
9092 AC_ARG_WITH(export-syms,
9093         [  --with-export-syms=XXX  limit exported symbols using libtool],
9094         [with_export_syms=$withval],
9095         [with_export_syms=no])
9096 if test "x$with_export_syms" = xyes
9097 then
9098         with_export_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).sym'
9099         AC_SUBST(PACKAGE)
9100 fi
9101 AC_MSG_RESULT($with_export_syms)
9102 if test "x$with_export_syms" != xno
9103 then
9104         EXPORT_SYMS="-export-symbols $with_export_syms"
9105         AC_SUBST(EXPORT_SYMS)
9106 fi
9107 ])dnl
9108 dnl ---------------------------------------------------------------------------
9109 dnl CF_WITH_GPM version: 10 updated: 2017/04/29 18:32:18
9110 dnl -----------
9111 dnl
9112 dnl The option parameter (if neither yes/no) is assumed to be the name of
9113 dnl the gpm library, e.g., for dynamic loading.
9114 AC_DEFUN([CF_WITH_GPM],
9115 [
9116 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
9117 AC_ARG_WITH(gpm,
9118         [  --with-gpm              use Alessandro Rubini's GPM library],
9119         [with_gpm=$withval],
9120         [with_gpm=maybe])
9121 AC_MSG_RESULT($with_gpm)
9122
9123 if test "$with_gpm" != no ; then
9124         AC_CHECK_HEADER(gpm.h,[
9125                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
9126                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
9127                         CF_VERBOSE(assuming we really have GPM library)
9128                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
9129                         with_gpm=yes
9130                 else
9131                         AC_CHECK_LIB(gpm,Gpm_Open,[with_gpm=yes],[
9132                                 if test "$with_gpm" = maybe; then
9133                                         AC_MSG_WARN(Cannot link with GPM library)
9134                                         with_gpm=no
9135                                 else
9136                                         AC_MSG_ERROR(Cannot link with GPM library)
9137                                 fi
9138                         ])
9139                 fi
9140         ],[
9141                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
9142                 with_gpm=no
9143         ])
9144 fi
9145 ])
9146 dnl ---------------------------------------------------------------------------
9147 dnl CF_WITH_LIBTOOL version: 36 updated: 2021/01/01 13:31:04
9148 dnl ---------------
9149 dnl Provide a configure option to incorporate libtool.  Define several useful
9150 dnl symbols for the makefile rules.
9151 dnl
9152 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
9153 dnl macros from libtool.m4 which is in the aclocal directory of automake.
9154 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
9155 dnl But that still does not work properly since the macro is expanded outside
9156 dnl the CF_WITH_LIBTOOL macro:
9157 dnl
9158 dnl     #!/bin/sh
9159 dnl     ACLOCAL=`aclocal --print-ac-dir`
9160 dnl     if test -z "$ACLOCAL" ; then
9161 dnl             echo cannot find aclocal directory
9162 dnl             exit 1
9163 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
9164 dnl             echo cannot find libtool.m4 file
9165 dnl             exit 1
9166 dnl     fi
9167 dnl
9168 dnl     LOCAL=aclocal.m4
9169 dnl     ORIG=aclocal.m4.orig
9170 dnl
9171 dnl     trap "mv $ORIG $LOCAL" 0 1 2 3 15
9172 dnl     rm -f $ORIG
9173 dnl     mv $LOCAL $ORIG
9174 dnl
9175 dnl     # sed the LIBTOOL= assignment to omit the current directory?
9176 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
9177 dnl     cat $ORIG >>$LOCAL
9178 dnl
9179 dnl     autoconf-257 $*
9180 dnl
9181 AC_DEFUN([CF_WITH_LIBTOOL],
9182 [
9183 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
9184 ifdef([AC_PROG_LIBTOOL],,[
9185 LIBTOOL=
9186 ])
9187 # common library maintenance symbols that are convenient for libtool scripts:
9188 LIB_CREATE='${AR} -cr'
9189 LIB_OBJECT='${OBJECTS}'
9190 LIB_SUFFIX=.a
9191 LIB_PREP="$RANLIB"
9192
9193 # symbols used to prop libtool up to enable it to determine what it should be
9194 # doing:
9195 LIB_CLEAN=
9196 LIB_COMPILE=
9197 LIB_LINK='${CC}'
9198 LIB_INSTALL=
9199 LIB_UNINSTALL=
9200
9201 AC_MSG_CHECKING(if you want to build libraries with libtool)
9202 AC_ARG_WITH(libtool,
9203         [  --with-libtool          generate libraries with libtool],
9204         [with_libtool=$withval],
9205         [with_libtool=no])
9206 AC_MSG_RESULT($with_libtool)
9207 if test "$with_libtool" != "no"; then
9208 ifdef([AC_PROG_LIBTOOL],[
9209         # missing_content_AC_PROG_LIBTOOL{{
9210         AC_PROG_LIBTOOL
9211         # missing_content_AC_PROG_LIBTOOL}}
9212 ],[
9213         if test "$with_libtool" != "yes" ; then
9214                 CF_PATH_SYNTAX(with_libtool)
9215                 LIBTOOL=$with_libtool
9216         else
9217                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
9218                 CF_LIBTOOL_VERSION
9219                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
9220                 then
9221                         CF_FORGET_TOOL(LIBTOOL)
9222                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
9223                         CF_LIBTOOL_VERSION
9224                 fi
9225         fi
9226         if test -z "$LIBTOOL" ; then
9227                 AC_MSG_ERROR(Cannot find libtool)
9228         fi
9229 ])dnl
9230         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${libdir} ${LIBTOOL_VERSION} `cut -f1 ${top_srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
9231         LIB_OBJECT='${OBJECTS:.o=.lo}'
9232         LIB_SUFFIX=.la
9233         LIB_CLEAN='${LIBTOOL} --mode=clean'
9234         LIB_COMPILE='${LIBTOOL} --mode=compile'
9235         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
9236         LIB_INSTALL='${LIBTOOL} --mode=install'
9237         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
9238         LIB_PREP=:
9239
9240         CF_CHECK_LIBTOOL_VERSION
9241
9242         # special hack to add -no-undefined (which libtool should do for itself)
9243         LT_UNDEF=
9244         case "$cf_cv_system_name" in
9245         (cygwin*|msys*|mingw32*|os2*|uwin*|aix[[4-7]])
9246                 LT_UNDEF=-no-undefined
9247                 ;;
9248         esac
9249         AC_SUBST([LT_UNDEF])
9250
9251         # special hack to add --tag option for C++ compiler
9252         case "$cf_cv_libtool_version" in
9253         (1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*)
9254                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
9255                 LIBTOOL="$LIBTOOL --tag=CC"
9256                 ;;
9257         (*)
9258                 LIBTOOL_CXX="$LIBTOOL"
9259                 ;;
9260         esac
9261 else
9262         LIBTOOL=""
9263         LIBTOOL_CXX=""
9264 fi
9265
9266 test -z "$LIBTOOL" && ECHO_LT=
9267
9268 AC_SUBST(LIBTOOL)
9269 AC_SUBST(LIBTOOL_CXX)
9270 AC_SUBST(LIBTOOL_OPTS)
9271
9272 AC_SUBST(LIB_CREATE)
9273 AC_SUBST(LIB_OBJECT)
9274 AC_SUBST(LIB_SUFFIX)
9275 AC_SUBST(LIB_PREP)
9276
9277 AC_SUBST(LIB_CLEAN)
9278 AC_SUBST(LIB_COMPILE)
9279 AC_SUBST(LIB_LINK)
9280 AC_SUBST(LIB_INSTALL)
9281 AC_SUBST(LIB_UNINSTALL)
9282
9283 ])dnl
9284 dnl ---------------------------------------------------------------------------
9285 dnl CF_WITH_LIBTOOL_OPTS version: 4 updated: 2015/04/17 21:13:04
9286 dnl --------------------
9287 dnl Allow user to pass additional libtool options into the library creation
9288 dnl and link steps.  The main use for this is to do something like
9289 dnl     ./configure --with-libtool-opts=-static
9290 dnl to get the same behavior as automake-flavored
9291 dnl     ./configure --enable-static
9292 AC_DEFUN([CF_WITH_LIBTOOL_OPTS],[
9293 AC_MSG_CHECKING(for additional libtool options)
9294 AC_ARG_WITH(libtool-opts,
9295         [  --with-libtool-opts=XXX specify additional libtool options],
9296         [with_libtool_opts=$withval],
9297         [with_libtool_opts=no])
9298 AC_MSG_RESULT($with_libtool_opts)
9299
9300 case .$with_libtool_opts in
9301 (.yes|.no|.)
9302         ;;
9303 (*)
9304         LIBTOOL_OPTS="$LIBTOOL_OPTS $with_libtool_opts"
9305         ;;
9306 esac
9307
9308 AC_SUBST(LIBTOOL_OPTS)
9309 ])dnl
9310 dnl ---------------------------------------------------------------------------
9311 dnl CF_WITH_LIB_BASENAME version: 1 updated: 2020/03/07 20:05:14
9312 dnl --------------------
9313 dnl Allow for overriding the basename of a library, i.e., the part to which
9314 dnl prefixes/suffixes are attached.
9315 dnl
9316 dnl $1 = variable to set
9317 dnl $2 = option name
9318 dnl $3 = default basename for library, if omitted use $2
9319 AC_DEFUN([CF_WITH_LIB_BASENAME],
9320 [
9321 AC_MSG_CHECKING(for desired basename for $2 library)
9322 AC_ARG_WITH($2-libname,
9323         [  --with-$2-libname=XXX override ifelse($3,,$2,$3) basename of library],
9324         [with_lib_basename=$withval],
9325         [with_lib_basename=ifelse($3,,$2,$3)])
9326 $1="$with_lib_basename"
9327
9328 case "x[$]$1" in
9329 (x|xno|xnone|xyes)
9330         $1=ifelse($3,,$2,$3)
9331         ;;
9332 (*)
9333         ;;
9334 esac
9335
9336 AC_MSG_RESULT([$]$1)
9337 AC_SUBST($1)
9338 ])dnl
9339 dnl ---------------------------------------------------------------------------
9340 dnl CF_WITH_LIB_PREFIX version: 2 updated: 2021/01/01 16:53:59
9341 dnl ------------------
9342 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
9343 dnl "lib" prefix, e.g., because it used the dll naming convention.
9344 dnl
9345 dnl $1 = variable to set
9346 AC_DEFUN([CF_WITH_LIB_PREFIX],
9347 [
9348 AC_MSG_CHECKING(if you want to have a library-prefix)
9349 AC_ARG_WITH(lib-prefix,
9350         [  --with-lib-prefix       override library-prefix],
9351         [with_lib_prefix=$withval],
9352         [with_lib_prefix=auto])
9353 AC_MSG_RESULT($with_lib_prefix)
9354
9355 if test "$with_lib_prefix" = auto
9356 then
9357         CF_LIB_PREFIX($1)
9358 elif test "$with_lib_prefix" = no
9359 then
9360         LIB_PREFIX=
9361 else
9362         LIB_PREFIX=$with_lib_prefix
9363 fi
9364 ])dnl
9365 dnl ---------------------------------------------------------------------------
9366 dnl CF_WITH_PATH version: 12 updated: 2021/09/04 06:35:04
9367 dnl ------------
9368 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
9369 dnl defaulting to yes/no.
9370 dnl
9371 dnl $1 = option name
9372 dnl $2 = help-text
9373 dnl $3 = environment variable to set
9374 dnl $4 = default value, shown in the help-message, must be a constant
9375 dnl $5 = default value, if it is an expression & cannot be in the help-message
9376 dnl
9377 AC_DEFUN([CF_WITH_PATH],
9378 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
9379 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
9380 if ifelse([$5],,true,[test -n "$5"]) ; then
9381 CF_PATH_SYNTAX(withval)
9382 fi
9383 eval $3="$withval"
9384 AC_SUBST($3)dnl
9385 ])dnl
9386 dnl ---------------------------------------------------------------------------
9387 dnl CF_WITH_PATHLIST version: 13 updated: 2021/09/04 06:35:04
9388 dnl ----------------
9389 dnl Process an option specifying a list of colon-separated paths.
9390 dnl
9391 dnl $1 = option name
9392 dnl $2 = help-text
9393 dnl $3 = environment variable to set
9394 dnl $4 = default value, shown in the help-message, must be a constant
9395 dnl $5 = default value, if it is an expression & cannot be in the help-message
9396 dnl $6 = flag to tell if we want to define or substitute
9397 dnl
9398 AC_DEFUN([CF_WITH_PATHLIST],[
9399 AC_REQUIRE([CF_PATHSEP])
9400 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
9401 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
9402
9403 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
9404 cf_dst_path=
9405 for cf_src_path in $withval
9406 do
9407   CF_PATH_SYNTAX(cf_src_path)
9408   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
9409   cf_dst_path="${cf_dst_path}${cf_src_path}"
9410 done
9411 IFS="$ac_save_ifs"
9412
9413 ifelse($6,define,[
9414 # Strip single quotes from the value, e.g., when it was supplied as a literal
9415 # for $4 or $5.
9416 case "$cf_dst_path" in
9417 (\'*)
9418   cf_dst_path="`echo "$cf_dst_path" |sed -e s/\'// -e s/\'\$//`"
9419   ;;
9420 esac
9421 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
9422 ])
9423
9424 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
9425 # so we have to check/work around.  We do prefer the result of "eval"...
9426 eval cf_dst_eval="$cf_dst_path"
9427 case "x$cf_dst_eval" in
9428 (xNONE*)
9429         $3=$cf_dst_path
9430         ;;
9431 (*)
9432         $3="$cf_dst_eval"
9433         ;;
9434 esac
9435 AC_SUBST($3)dnl
9436
9437 ])dnl
9438 dnl ---------------------------------------------------------------------------
9439 dnl CF_WITH_PATH_PROG version: 1 updated: 2019/06/30 19:44:43
9440 dnl -----------------
9441 dnl Check for a given program, like CF_PATH_PROG, but allow override using a
9442 dnl "--with-xxx" option.
9443 dnl
9444 dnl Parameters:
9445 dnl             $1 = environment variable to set/update
9446 dnl             $2 = program name
9447 dnl             $3 = help-text
9448 dnl             $4 = $PATH
9449 AC_DEFUN([CF_WITH_PATH_PROG],[
9450 AC_ARG_WITH($2-path,
9451         [  --with-$2-path=XXX     specify path of $2 ifelse($3,,,$3)],
9452         [AC_MSG_CHECKING(for $2 program ifelse($3,,,$3))
9453                 $1=$withval
9454                 AC_MSG_RESULT([$]$1)
9455                 CF_PATH_SYNTAX($1)
9456         ],
9457         [CF_PATH_PROG($1,$2,,ifelse($4,,,$4))
9458                 if test -z "[$]$1"
9459                 then
9460                         AC_MSG_WARN(no $2 program found ifelse($3,,,$3))
9461                 fi
9462         ])
9463 ])
9464 dnl ---------------------------------------------------------------------------
9465 dnl CF_WITH_PCRE2 version: 6 updated: 2021/08/11 20:35:34
9466 dnl -------------
9467 dnl Add PCRE2 (Perl-compatible regular expressions v2) to the build if it is
9468 dnl available and the user requests it.  Assume the application will otherwise
9469 dnl use the POSIX interface.
9470 dnl
9471 dnl TODO allow $withval to specify package location
9472 AC_DEFUN([CF_WITH_PCRE2],
9473 [
9474 AC_REQUIRE([CF_PKG_CONFIG])
9475
9476 AC_MSG_CHECKING(if you want to use PCRE2 for regular-expressions)
9477 AC_ARG_WITH(pcre2,
9478         [  --with-pcre2            use PCRE2 for regular-expressions])
9479 test -z "$with_pcre2" && with_pcre2=no
9480 AC_MSG_RESULT($with_pcre2)
9481
9482 if test "x$with_pcre2" != xno ; then
9483         cf_with_pcre2_ok=no
9484         for cf_with_pcre2 in libpcre2 libpcre2-posix libpcre
9485         do
9486                 CF_TRY_PKG_CONFIG($cf_with_pcre2,[cf_with_pcre2_ok=yes; break])
9487         done
9488         cf_with_pcre2_ok=yes || AC_MSG_ERROR(Cannot find PCRE2 library)
9489
9490         AC_DEFINE(HAVE_LIB_PCRE2,1,[Define to 1 if we can/should compile with the PCRE2 library])
9491
9492         # if pkgconfig gave no results, look for the libraries directly
9493         case "$LIBS" in
9494         (*pcre2-posix*|*pcreposix*)
9495                 ;;
9496         (*)
9497                 AC_CHECK_LIB(pcre2-posix,regcomp,[
9498                         CF_ADD_LIB(pcre2-posix)],
9499                         [AC_CHECK_LIB(pcreposix,regcomp,[
9500                          CF_ADD_LIB(pcreposix)
9501                         ],[AC_MSG_ERROR(Cannot find PCRE2 POSIX library)])])
9502                 ;;
9503         esac
9504
9505         # either way, check for the library header files
9506         AC_CHECK_HEADERS(pcre2posix.h pcreposix.h)
9507         AC_CHECK_FUNCS(PCRE2regcomp)
9508 fi
9509 ])dnl
9510 dnl ---------------------------------------------------------------------------
9511 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 21 updated: 2023/01/22 13:37:42
9512 dnl -------------------------
9513 dnl Allow the choice of the pkg-config library directory to be overridden.
9514 dnl
9515 dnl pkg-config uses a search-list built from these colon-separated lists of
9516 dnl directories:
9517 dnl a) $PKG_CONFIG_PATH (tested first, added if set)
9518 dnl b) $PKG_CONFIG_LIBDIR (tested second, added if set)
9519 dnl c) builtin-list (added if $PKG_CONFIG_LIBDIR is not set)
9520 dnl
9521 dnl pkgconf (used with some systems such as FreeBSD in place of pkg-config)
9522 dnl optionally ignores $PKG_CONFIG_LIBDIR.  Very old versions of pkg-config,
9523 dnl e.g., Solaris 10 also do not recognize $PKG_CONFIG_LIBDIR.
9524 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
9525
9526 case "$PKG_CONFIG" in
9527 (no|none|yes)
9528         AC_MSG_CHECKING(for pkg-config library directory)
9529         ;;
9530 (*)
9531         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
9532         ;;
9533 esac
9534
9535 # if $PKG_CONFIG_LIBDIR is set, try to use that
9536 if test -n "$PKG_CONFIG_PATH"; then
9537         cf_search_path=`echo "$PKG_CONFIG_PATH" | sed -e 's/:/ /g' -e 's,^[[    ]]*,,' -e 's,[[         ]]*$,,'`
9538 elif test -n "$PKG_CONFIG_LIBDIR"; then
9539         cf_search_path=`echo "$PKG_CONFIG_LIBDIR" | sed -e 's/:/ /g' -e 's,^[[  ]]*,,' -e 's,[[         ]]*$,,'`
9540 else
9541         cf_search_path=auto
9542 fi
9543
9544 # if the option is used, let that override.  otherwise default to "libdir"
9545 AC_ARG_WITH(pkg-config-libdir,
9546         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
9547         [cf_search_path=$withval],
9548         [test "x$PKG_CONFIG" != xnone && test -z "$cf_search_path" && cf_search_path=libdir])
9549
9550 case "x$cf_search_path" in
9551 (xlibdir)
9552         PKG_CONFIG_LIBDIR='${libdir}/pkgconfig'
9553         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
9554         cf_search_path=
9555         ;;
9556 (x)
9557         ;;
9558 (x/*\ *)
9559         PKG_CONFIG_LIBDIR=
9560         ;;
9561 (x/*)
9562         PKG_CONFIG_LIBDIR="$cf_search_path"
9563         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
9564         cf_search_path=
9565         ;;
9566 (xyes|xauto)
9567         AC_MSG_RESULT(auto)
9568         cf_search_path=
9569         # Look for the library directory using the same prefix as the executable
9570         AC_MSG_CHECKING(for search-list)
9571         if test "x$PKG_CONFIG" != xnone
9572         then
9573                 # works for pkg-config since version 0.24 (2009)
9574                 # works for pkgconf since version 0.8.3 (2012)
9575                 for cf_pkg_program in \
9576                         `echo "$PKG_CONFIG" | sed -e 's,^.*/,,'` \
9577                         pkg-config \
9578                         pkgconf
9579                 do
9580                         cf_search_path=`"$PKG_CONFIG" --variable=pc_path "$cf_pkg_program" 2>/dev/null | tr : ' '`
9581                         test -n "$cf_search_path" && break
9582                 done
9583
9584                 # works for pkg-config since import in 2005 of original 2001 HP code.
9585                 test -z "$cf_search_path" && \
9586                 cf_search_path=`
9587                 "$PKG_CONFIG" --debug --exists no-such-package 2>&1 | $AWK "\
9588 /^Scanning directory (#[1-9][0-9]* )?'.*'$/{ \
9589         sub(\"^[[^']]*'\",\"\"); \
9590         sub(\"'.*\",\"\"); \
9591         printf \" %s\", \\[$]0; } \
9592 { next; } \
9593 "`
9594         fi
9595
9596         AC_MSG_RESULT($cf_search_path)
9597         ;;
9598 (*)
9599         AC_MSG_ERROR(Unexpected option value: $cf_search_path)
9600         ;;
9601 esac
9602
9603 if test -n "$cf_search_path"
9604 then
9605         AC_MSG_CHECKING(for first directory)
9606         cf_pkg_config_path=none
9607         for cf_config in $cf_search_path
9608         do
9609                 if test -d "$cf_config"
9610                 then
9611                         cf_pkg_config_path=$cf_config
9612                         break
9613                 fi
9614         done
9615         AC_MSG_RESULT($cf_pkg_config_path)
9616
9617         if test "x$cf_pkg_config_path" != xnone ; then
9618                 # limit this to the first directory found
9619                 PKG_CONFIG_LIBDIR="$cf_pkg_config_path"
9620         fi
9621
9622         if test -z "$PKG_CONFIG_LIBDIR" && test -n "$cf_search_path"
9623         then
9624                 AC_MSG_CHECKING(for workaround)
9625                 if test "$prefix" = "NONE" ; then
9626                         cf_prefix="$ac_default_prefix"
9627                 else
9628                         cf_prefix="$prefix"
9629                 fi
9630                 eval cf_libdir=$libdir
9631                 cf_libdir=`echo "$cf_libdir" | sed -e "s,^NONE,$cf_prefix,"`
9632                 cf_backup=
9633                 for cf_config in $cf_search_path
9634                 do
9635                         case $cf_config in
9636                         $cf_libdir/pkgconfig)
9637                                 PKG_CONFIG_LIBDIR=$cf_libdir/pkgconfig
9638                                 break
9639                                 ;;
9640                         *)
9641                                 test -z "$cf_backup" && cf_backup=$cf_config
9642                                 ;;
9643                         esac
9644                 done
9645                 test -z "$PKG_CONFIG_LIBDIR" && PKG_CONFIG_LIBDIR=$cf_backup
9646                 AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
9647         fi
9648 fi
9649
9650 AC_SUBST(PKG_CONFIG_LIBDIR)
9651 ])dnl
9652 dnl ---------------------------------------------------------------------------
9653 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
9654 dnl ---------------
9655 dnl Check for POSIX thread library.
9656 AC_DEFUN([CF_WITH_PTHREAD],
9657 [
9658 AC_MSG_CHECKING(if you want to link with the pthread library)
9659 AC_ARG_WITH(pthread,
9660         [  --with-pthread          use POSIX thread library],
9661         [with_pthread=$withval],
9662         [with_pthread=no])
9663 AC_MSG_RESULT($with_pthread)
9664
9665 if test "$with_pthread" != no ; then
9666         AC_CHECK_HEADER(pthread.h,[
9667         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
9668
9669         for cf_lib_pthread in pthread c_r
9670         do
9671             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
9672             cf_save_LIBS="$LIBS"
9673             CF_ADD_LIB($cf_lib_pthread)
9674             AC_TRY_LINK([
9675 #include <pthread.h>
9676 ],[
9677                 int rc = pthread_create(0,0,0,0);
9678                 int r2 = pthread_mutexattr_settype(0, 0);
9679 ],[with_pthread=yes],[with_pthread=no])
9680             LIBS="$cf_save_LIBS"
9681             AC_MSG_RESULT($with_pthread)
9682             test "$with_pthread" = yes && break
9683         done
9684
9685         if test "$with_pthread" = yes ; then
9686             CF_ADD_LIB($cf_lib_pthread)
9687             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
9688         else
9689             AC_MSG_ERROR(Cannot link with pthread library)
9690         fi
9691         ])
9692 fi
9693 ])
9694 dnl ---------------------------------------------------------------------------
9695 dnl CF_WITH_REL_VERSION version: 2 updated: 2023/05/06 18:18:18
9696 dnl -------------------
9697 dnl Allow library's release-version to be overridden.  Generally this happens when a
9698 dnl packager has incremented the release-version past that used in the original package,
9699 dnl and wishes to keep doing this.
9700 dnl
9701 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
9702 dnl and {package}_MINOR symbols
9703 dnl symbol.
9704 AC_DEFUN([CF_WITH_REL_VERSION],[
9705 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
9706 AC_ARG_WITH(rel-version,
9707 [  --with-rel-version=XXX  override derived release version],
9708 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
9709  cf_cv_rel_version=$withval])
9710 ifelse($1,,[
9711  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
9712 ],[
9713  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
9714  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
9715  test -n "$1_MINOR" || $1_MINOR=0
9716  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
9717  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
9718 ])
9719 ])dnl
9720 dnl ---------------------------------------------------------------------------
9721 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
9722 dnl ----------------
9723 dnl If we can compile with sysmouse, make it available unless it is not wanted.
9724 AC_DEFUN([CF_WITH_SYSMOUSE],[
9725 # not everyone has "test -c"
9726 if test -c /dev/sysmouse 2>/dev/null ; then
9727 AC_MSG_CHECKING(if you want to use sysmouse)
9728 AC_ARG_WITH(sysmouse,
9729         [  --with-sysmouse         use sysmouse (FreeBSD console)],
9730         [cf_with_sysmouse=$withval],
9731         [cf_with_sysmouse=maybe])
9732         if test "$cf_with_sysmouse" != no ; then
9733         AC_TRY_COMPILE([
9734 #include <osreldate.h>
9735 #if (__FreeBSD_version >= 400017)
9736 #include <sys/consio.h>
9737 #include <sys/fbio.h>
9738 #else
9739 #include <machine/console.h>
9740 #endif
9741 ],[
9742         struct mouse_info the_mouse;
9743         ioctl(0, CONS_MOUSECTL, &the_mouse);
9744 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
9745         fi
9746 AC_MSG_RESULT($cf_with_sysmouse)
9747 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
9748 fi
9749 ])dnl
9750 dnl ---------------------------------------------------------------------------
9751 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
9752 dnl ---------------
9753 dnl For testing, override the derived host system-type which is used to decide
9754 dnl things such as the linker commands used to build shared libraries.  This is
9755 dnl normally chosen automatically based on the type of system which you are
9756 dnl building on.  We use it for testing the configure script.
9757 dnl
9758 dnl This is different from the --host option: it is used only for testing parts
9759 dnl of the configure script which would not be reachable with --host since that
9760 dnl relies on the build environment being real, rather than mocked up.
9761 AC_DEFUN([CF_WITH_SYSTYPE],[
9762 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
9763 AC_ARG_WITH(system-type,
9764         [  --with-system-type=XXX  test: override derived host system-type],
9765 [AC_MSG_WARN(overriding system type to $withval)
9766         cf_cv_system_name=$withval
9767         host_os=$withval
9768 ])
9769 ])dnl
9770 dnl ---------------------------------------------------------------------------
9771 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
9772 dnl ----------------
9773 AC_DEFUN([CF_WITH_VALGRIND],[
9774 CF_NO_LEAKS_OPTION(valgrind,
9775         [  --with-valgrind         test: use valgrind],
9776         [USE_VALGRIND])
9777 ])dnl
9778 dnl ---------------------------------------------------------------------------
9779 dnl CF_WITH_VERSIONED_SYMS version: 10 updated: 2021/01/04 18:48:01
9780 dnl ----------------------
9781 dnl Use this when building shared library with ELF, to markup symbols with the
9782 dnl version identifier from the given input file.  Generally that identifier is
9783 dnl the same as the SONAME at which the symbol was first introduced.
9784 dnl
9785 dnl $1 = basename of the ".map" file (default $PACKAGE)
9786 AC_DEFUN([CF_WITH_VERSIONED_SYMS],
9787 [AC_REQUIRE([AC_PROG_FGREP])dnl
9788 AC_REQUIRE([AC_PROG_EGREP])dnl
9789
9790 AC_MSG_CHECKING(if versioned-symbols file should be used)
9791 AC_ARG_WITH(versioned-syms,
9792         [  --with-versioned-syms=X markup versioned symbols using ld],
9793         [with_versioned_syms=$withval],
9794         [with_versioned_syms=no])
9795 case "x$with_versioned_syms" in
9796 (xyes)
9797         with_versioned_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).map'
9798         AC_SUBST(PACKAGE)
9799         ;;
9800 (xno)
9801         ;;
9802 (x/*)
9803         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
9804         ;;
9805 (*)
9806         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
9807         with_versioned_syms=`pwd`/"$with_versioned_syms"
9808         ;;
9809 esac
9810 AC_MSG_RESULT($with_versioned_syms)
9811
9812 RESULTING_SYMS=
9813 VERSIONED_SYMS=
9814 WILDCARD_SYMS=
9815
9816 if test "x$with_versioned_syms" != xno
9817 then
9818         RESULTING_SYMS=$with_versioned_syms
9819         case "x$MK_SHARED_LIB" in
9820         (*-Wl,*)
9821                 VERSIONED_SYMS="-Wl,--version-script,\${RESULTING_SYMS}"
9822                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-Wl,%\\[$]{VERSIONED_SYMS} -Wl,%"`
9823                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
9824                 ;;
9825         (*-dy\ *)
9826                 VERSIONED_SYMS="-Wl,-M,\${RESULTING_SYMS}"
9827                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-dy%\\[$]{VERSIONED_SYMS} -dy%"`
9828                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
9829                 ;;
9830         (*)
9831                 AC_MSG_WARN(this system does not support versioned-symbols)
9832                 ;;
9833         esac
9834
9835         # Linux ld can selectively override scope, e.g., of symbols beginning with
9836         # "_" by first declaring some as global, and then using a wildcard to
9837         # declare the others as local.  Some other loaders cannot do this.  Check
9838         # by constructing a (very) simple shared library and inspecting its
9839         # symbols.
9840         if test "x$VERSIONED_SYMS" != "x"
9841         then
9842                 AC_MSG_CHECKING(if wildcards can be used to selectively omit symbols)
9843                 WILDCARD_SYMS=no
9844
9845                 # make sources
9846                 rm -f conftest.*
9847
9848                 cat >conftest.ver <<EOF
9849 module_1.0 {
9850 global:
9851         globalf1;
9852 local:
9853         localf1;
9854 };
9855 module_2.0 {
9856 global:
9857         globalf2;
9858 local:
9859         localf2;
9860         _*;
9861 } module_1.0;
9862 submodule_1.0 {
9863 global:
9864         subglobalf1;
9865         _ismissing;
9866 local:
9867         sublocalf1;
9868 };
9869 submodule_2.0 {
9870 global:
9871         subglobalf2;
9872 local:
9873         sublocalf2;
9874         _*;
9875 } submodule_1.0;
9876 EOF
9877                 cat >conftest.$ac_ext <<EOF
9878 #line __oline__ "configure"
9879 int     _ismissing(void) { return 1; }
9880 int     _localf1(void) { return 1; }
9881 int     _localf2(void) { return 2; }
9882 int     globalf1(void) { return 1; }
9883 int     globalf2(void) { return 2; }
9884 int     _sublocalf1(void) { return 1; }
9885 int     _sublocalf2(void) { return 2; }
9886 int     subglobalf1(void) { return 1; }
9887 int     subglobalf2(void) { return 2; }
9888 EOF
9889                 cat >conftest.mk <<EOF
9890 CC=${CC}
9891 CFLAGS=${CFLAGS}
9892 CPPFLAGS=${CPPFLAGS}
9893 LDFLAGS=${LDFLAGS}
9894 LIBS=${LIBS}
9895 VERSIONED_SYMS=${VERSIONED_SYMS}
9896 RESULTING_SYMS=conftest.ver
9897 MK_SHARED_LIB=${MK_SHARED_LIB}
9898 conftest.so: conftest.$ac_cv_objext
9899                 \$(MK_SHARED_LIB) conftest.$ac_cv_objext
9900 EOF
9901
9902                 # compile source, make library
9903                 if make -f conftest.mk 2>&AC_FD_CC >/dev/null
9904                 then
9905                         # test for missing symbol in either Data or Text section
9906                         cf_missing="`nm -P conftest.so 2>&AC_FD_CC |${FGREP-fgrep} _ismissing | ${EGREP-egrep} '[[      ]][[DT]][[      ]]'`"
9907                         test -n "$cf_missing" && WILDCARD_SYMS=yes
9908                 fi
9909                 AC_MSG_RESULT($WILDCARD_SYMS)
9910                 rm -f conftest.*
9911         fi
9912 fi
9913 AC_SUBST(RESULTING_SYMS)
9914 AC_SUBST(VERSIONED_SYMS)
9915 AC_SUBST(WILDCARD_SYMS)
9916 ])dnl
9917 dnl ---------------------------------------------------------------------------
9918 dnl CF_WITH_X11_RGB version: 2 updated: 2019/12/31 08:53:54
9919 dnl ---------------
9920 dnl Handle configure option "--with-x11-rgb", setting these shell
9921 dnl variables:
9922 dnl
9923 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
9924 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
9925 dnl
9926 dnl Most Linux's use this:
9927 dnl     /usr/share/X11/rgb.txt
9928 dnl Debian uses this:
9929 dnl     /etc/X11/rgb.txt
9930 dnl DragonFlyBSD ports uses this:
9931 dnl     /usr/pkg/lib/X11/rgb.txt
9932 dnl FreeBSD ports use these:
9933 dnl     /usr/local/lib/X11/rgb.txt
9934 dnl     /usr/local/share/X11/rgb.txt
9935 dnl Mandriva has these:
9936 dnl     /usr/lib/X11/rgb.txt
9937 dnl     /usr/lib64/X11/rgb.txt
9938 dnl NetBSD has these
9939 dnl     /usr/X11R7/lib/X11/rgb.txt
9940 dnl OpenSolaris uses
9941 dnl     32-bit:
9942 dnl     /usr/X11/etc/X11/rgb.txt
9943 dnl     /usr/X11/share/X11/rgb.txt
9944 dnl     /usr/X11/lib/X11/rgb.txt
9945 dnl OSX uses
9946 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
9947 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
9948 dnl     64-bit:
9949 dnl     /usr/X11/etc/X11/rgb.txt
9950 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
9951 dnl     /usr/X11/lib/amd64/X11/rgb.txt
9952 dnl Solaris10 uses (in this order):
9953 dnl     /usr/openwin/lib/X11/rgb.txt
9954 dnl     /usr/X11/lib/X11/rgb.txt
9955 AC_DEFUN([CF_WITH_X11_RGB],[
9956 AC_MSG_CHECKING(for X11 rgb file)
9957 AC_ARG_WITH(x11-rgb,
9958         [  --with-x11-rgb=FILE   file containing X11 rgb information (EPREFIX/lib/X11/rgb.txt)],
9959         [RGB_PATH=$withval],
9960         [RGB_PATH=auto])
9961
9962 if test "x[$]RGB_PATH" = xauto
9963 then
9964         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
9965         for cf_path in \
9966                 /opt/local/share/X11/rgb.txt \
9967                 /opt/X11/share/X11/rgb.txt \
9968                 /usr/share/X11/rgb.txt \
9969                 /usr/X11/share/X11/rgb.txt \
9970                 /usr/X11/lib/X11/rgb.txt \
9971                 /usr/lib/X11/rgb.txt \
9972                 /etc/X11/rgb.txt \
9973                 /usr/pkg/lib/X11/rgb.txt \
9974                 /usr/X11R7/lib/X11/rgb.txt \
9975                 /usr/X11R6/lib/X11/rgb.txt \
9976                 /usr/X11R5/lib/X11/rgb.txt \
9977                 /usr/X11R4/lib/X11/rgb.txt \
9978                 /usr/local/lib/X11/rgb.txt \
9979                 /usr/local/share/X11/rgb.txt \
9980                 /usr/lib64/X11/rgb.txt
9981         do
9982                 if test -f "$cf_path" ; then
9983                         RGB_PATH="$cf_path"
9984                         break
9985                 fi
9986         done
9987 else
9988         cf_path=$RGB_PATH
9989         CF_PATH_SYNTAX(cf_path)
9990 fi
9991
9992 AC_MSG_RESULT($RGB_PATH)
9993 AC_SUBST(RGB_PATH)
9994 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path",[Define to the full pathname of rgb.txt])
9995
9996 no_x11_rgb=
9997 if test "$RGB_PATH" = no
9998 then
9999         no_x11_rgb="#"
10000 fi
10001 AC_SUBST(no_x11_rgb)
10002 ])dnl
10003 dnl ---------------------------------------------------------------------------
10004 dnl CF_XOPEN_SOURCE version: 66 updated: 2023/04/03 04:19:37
10005 dnl ---------------
10006 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
10007 dnl or adapt to the vendor's definitions to get equivalent functionality,
10008 dnl without losing the common non-POSIX features.
10009 dnl
10010 dnl Parameters:
10011 dnl     $1 is the nominal value for _XOPEN_SOURCE
10012 dnl     $2 is the nominal value for _POSIX_C_SOURCE
10013 dnl
10014 dnl The default case prefers _XOPEN_SOURCE over _POSIX_C_SOURCE if the
10015 dnl implementation predefines it, because X/Open and most implementations agree
10016 dnl that the latter is a legacy or "aligned" value.
10017 dnl
10018 dnl Because _XOPEN_SOURCE is preferred, if defining _POSIX_C_SOURCE turns
10019 dnl that off, then refrain from setting _POSIX_C_SOURCE explicitly.
10020 dnl
10021 dnl References:
10022 dnl https://pubs.opengroup.org/onlinepubs/007904975/functions/xsh_chap02_02.html
10023 dnl https://docs.oracle.com/cd/E19253-01/816-5175/standards-5/index.html
10024 dnl https://www.gnu.org/software/libc/manual/html_node/Feature-Test-Macros.html
10025 AC_DEFUN([CF_XOPEN_SOURCE],[
10026 AC_REQUIRE([AC_CANONICAL_HOST])
10027 AC_REQUIRE([CF_POSIX_VISIBLE])
10028
10029 if test "$cf_cv_posix_visible" = no; then
10030
10031 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
10032 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
10033 cf_xopen_source=
10034
10035 case "$host_os" in
10036 (aix[[4-7]]*)
10037         cf_xopen_source="-D_ALL_SOURCE"
10038         ;;
10039 (darwin[[0-8]].*)
10040         cf_xopen_source="-D_APPLE_C_SOURCE"
10041         ;;
10042 (darwin*)
10043         cf_xopen_source="-D_DARWIN_C_SOURCE"
10044         cf_XOPEN_SOURCE=
10045         ;;
10046 (freebsd*|dragonfly*|midnightbsd*)
10047         # 5.x headers associate
10048         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
10049         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
10050         cf_POSIX_C_SOURCE=200112L
10051         cf_XOPEN_SOURCE=600
10052         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
10053         ;;
10054 (hpux11*)
10055         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
10056         ;;
10057 (hpux*)
10058         cf_xopen_source="-D_HPUX_SOURCE"
10059         ;;
10060 (irix[[56]].*)
10061         cf_xopen_source="-D_SGI_SOURCE"
10062         cf_XOPEN_SOURCE=
10063         ;;
10064 (linux*gnu|linux*gnuabi64|linux*gnuabin32|linux*gnueabi|linux*gnueabihf|linux*gnux32|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin|msys|mingw*)
10065         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
10066         ;;
10067 (minix*)
10068         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
10069         ;;
10070 (mirbsd*)
10071         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
10072         cf_XOPEN_SOURCE=
10073         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
10074         ;;
10075 (netbsd*)
10076         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
10077         ;;
10078 (openbsd[[6-9]]*)
10079         # OpenBSD 6.x has broken locale support, both compile-time and runtime.
10080         # see https://www.mail-archive.com/bugs@openbsd.org/msg13200.html
10081         # Abusing the conformance level is a workaround.
10082         AC_MSG_WARN(this system does not provide usable locale support)
10083         cf_xopen_source="-D_BSD_SOURCE"
10084         cf_XOPEN_SOURCE=700
10085         ;;
10086 (openbsd[[4-5]]*)
10087         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
10088         cf_xopen_source="-D_BSD_SOURCE"
10089         cf_XOPEN_SOURCE=600
10090         ;;
10091 (openbsd*)
10092         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
10093         ;;
10094 (osf[[45]]*)
10095         cf_xopen_source="-D_OSF_SOURCE"
10096         ;;
10097 (nto-qnx*)
10098         cf_xopen_source="-D_QNX_SOURCE"
10099         ;;
10100 (sco*)
10101         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
10102         ;;
10103 (solaris2.*)
10104         cf_xopen_source="-D__EXTENSIONS__"
10105         cf_cv_xopen_source=broken
10106         ;;
10107 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
10108         cf_XOPEN_SOURCE=
10109         cf_POSIX_C_SOURCE=
10110         ;;
10111 (*)
10112         CF_TRY_XOPEN_SOURCE
10113         cf_save_xopen_cppflags="$CPPFLAGS"
10114         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
10115         # Some of these niche implementations use copy/paste, double-check...
10116         if test "$cf_cv_xopen_source" = no ; then
10117                 CF_VERBOSE(checking if _POSIX_C_SOURCE interferes with _XOPEN_SOURCE)
10118                 AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,,[
10119                         AC_MSG_WARN(_POSIX_C_SOURCE definition is not usable)
10120                         CPPFLAGS="$cf_save_xopen_cppflags"])
10121         fi
10122         ;;
10123 esac
10124
10125 if test -n "$cf_xopen_source" ; then
10126         CF_APPEND_CFLAGS($cf_xopen_source,true)
10127 fi
10128
10129 dnl In anything but the default case, we may have system-specific setting
10130 dnl which is still not guaranteed to provide all of the entrypoints that
10131 dnl _XOPEN_SOURCE would yield.
10132 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
10133         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
10134         AC_TRY_COMPILE([#include <stdlib.h>],[
10135 #ifndef _XOPEN_SOURCE
10136 #error _XOPEN_SOURCE is not defined
10137 #endif],
10138         [cf_XOPEN_SOURCE_set=yes],
10139         [cf_XOPEN_SOURCE_set=no])
10140         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
10141         if test "$cf_XOPEN_SOURCE_set" = yes
10142         then
10143                 AC_TRY_COMPILE([#include <stdlib.h>],[
10144 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
10145 #error (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
10146 #endif],
10147                 [cf_XOPEN_SOURCE_set_ok=yes],
10148                 [cf_XOPEN_SOURCE_set_ok=no])
10149                 if test "$cf_XOPEN_SOURCE_set_ok" = no
10150                 then
10151                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
10152                 fi
10153         else
10154                 CF_TRY_XOPEN_SOURCE
10155         fi
10156 fi
10157 fi # cf_cv_posix_visible
10158 ])
10159 dnl ---------------------------------------------------------------------------
10160 dnl CF__SED_TRIMBLANKS version: 1 updated: 2021/01/02 09:31:20
10161 dnl ------------------
10162 dnl Trim something using sed, then trim extra whitespace
10163 dnl $1 = extra parameters, e.g., in CF_STRIP_G_OPT
10164 define([CF__SED_TRIMBLANKS],[sed ifelse($1,,,[$1] )-e 's%[[     ]]% %g' -e 's% [[ ]]*% %g' -e 's%^ %%' -e 's% [$]%%'])dnl
10165 dnl ---------------------------------------------------------------------------
10166 dnl CF__XOPEN_SOURCE_BODY version: 2 updated: 2023/02/18 17:41:25
10167 dnl ---------------------
10168 dnl body of test when test-compiling for _XOPEN_SOURCE check
10169 define([CF__XOPEN_SOURCE_BODY],
10170 [
10171 #ifndef _XOPEN_SOURCE
10172 #error _XOPEN_SOURCE is not defined
10173 #endif
10174 ])
10175 dnl ---------------------------------------------------------------------------
10176 dnl CF__XOPEN_SOURCE_HEAD version: 2 updated: 2023/02/18 17:41:25
10177 dnl ---------------------
10178 dnl headers to include when test-compiling for _XOPEN_SOURCE check
10179 define([CF__XOPEN_SOURCE_HEAD],
10180 [
10181 $ac_includes_default
10182 ])