ncurses 5.9 - patch 20150110
[ncurses.git] / aclocal.m4
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2014,2015 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: aclocal.m4,v 1.729 2015/01/10 22:05:24 tom Exp $
32 dnl Macros used in NCURSES auto-configuration script.
33 dnl
34 dnl These macros are maintained separately from NCURSES.  The copyright on
35 dnl this file applies to the aggregation of macros and does not affect use of
36 dnl these macros in other applications.
37 dnl
38 dnl See http://invisible-island.net/autoconf/ for additional information.
39 dnl
40 dnl ---------------------------------------------------------------------------
41 dnl ---------------------------------------------------------------------------
42 dnl AM_LANGINFO_CODESET version: 3 updated: 2002/10/27 23:21:42
43 dnl -------------------
44 dnl Inserted as requested by gettext 0.10.40
45 dnl File from /usr/share/aclocal
46 dnl codeset.m4
47 dnl ====================
48 dnl serial AM1
49 dnl
50 dnl From Bruno Haible.
51 AC_DEFUN([AM_LANGINFO_CODESET],
52 [
53   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
54     [AC_TRY_LINK([#include <langinfo.h>],
55       [char* cs = nl_langinfo(CODESET);],
56       am_cv_langinfo_codeset=yes,
57       am_cv_langinfo_codeset=no)
58     ])
59   if test $am_cv_langinfo_codeset = yes; then
60     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
61       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
62   fi
63 ])dnl
64 dnl ---------------------------------------------------------------------------
65 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
66 dnl ------------------
67 dnl Conditionally generate script according to whether we're using a given autoconf.
68 dnl
69 dnl $1 = version to compare against
70 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
71 dnl $3 = code to use if AC_ACVERSION is older than $1.
72 define([CF_ACVERSION_CHECK],
73 [
74 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
75 ifdef([m4_version_compare],
76 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
77 [CF_ACVERSION_COMPARE(
78 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
79 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
80 dnl ---------------------------------------------------------------------------
81 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
82 dnl --------------------
83 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
84 dnl                      MAJOR2, MINOR2, TERNARY2,
85 dnl                      PRINTABLE2, not FOUND, FOUND)
86 define([CF_ACVERSION_COMPARE],
87 [ifelse(builtin([eval], [$2 < $5]), 1,
88 [ifelse([$8], , ,[$8])],
89 [ifelse([$9], , ,[$9])])])dnl
90 dnl ---------------------------------------------------------------------------
91 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
92 dnl -------------------
93 dnl Construct the list of include-options for the C programs in the Ada95
94 dnl binding.
95 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
96 [
97 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
98 if test "$srcdir" != "."; then
99         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
100 fi
101 if test "$GCC" != yes; then
102         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
103 elif test "$includedir" != "/usr/include"; then
104         if test "$includedir" = '${prefix}/include' ; then
105                 if test x$prefix != x/usr ; then
106                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
107                 fi
108         else
109                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
110         fi
111 fi
112 AC_SUBST(ACPPFLAGS)
113 ])dnl
114 dnl ---------------------------------------------------------------------------
115 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
116 dnl ---------------
117 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
118 AC_DEFUN([CF_ADD_ADAFLAGS],[
119         ADAFLAGS="$ADAFLAGS $1"
120         AC_SUBST(ADAFLAGS)
121 ])dnl
122 dnl ---------------------------------------------------------------------------
123 dnl CF_ADD_CFLAGS version: 11 updated: 2014/07/22 05:32:57
124 dnl -------------
125 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
126 dnl The second parameter if given makes this macro verbose.
127 dnl
128 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
129 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
130 dnl confused by the quotes (which require backslashes to keep them usable).
131 AC_DEFUN([CF_ADD_CFLAGS],
132 [
133 cf_fix_cppflags=no
134 cf_new_cflags=
135 cf_new_cppflags=
136 cf_new_extra_cppflags=
137
138 for cf_add_cflags in $1
139 do
140 case $cf_fix_cppflags in
141 no)
142         case $cf_add_cflags in #(vi
143         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
144                 case $cf_add_cflags in
145                 -D*)
146                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
147
148                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
149                                 && test -z "${cf_tst_cflags}" \
150                                 && cf_fix_cppflags=yes
151
152                         if test $cf_fix_cppflags = yes ; then
153                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
154                                 continue
155                         elif test "${cf_tst_cflags}" = "\"'" ; then
156                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
157                                 continue
158                         fi
159                         ;;
160                 esac
161                 case "$CPPFLAGS" in
162                 *$cf_add_cflags) #(vi
163                         ;;
164                 *) #(vi
165                         case $cf_add_cflags in #(vi
166                         -D*)
167                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
168                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
169                                 ;;
170                         esac
171                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
172                         ;;
173                 esac
174                 ;;
175         *)
176                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
177                 ;;
178         esac
179         ;;
180 yes)
181         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
182
183         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
184
185         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
186                 && test -z "${cf_tst_cflags}" \
187                 && cf_fix_cppflags=no
188         ;;
189 esac
190 done
191
192 if test -n "$cf_new_cflags" ; then
193         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
194         CFLAGS="$CFLAGS $cf_new_cflags"
195 fi
196
197 if test -n "$cf_new_cppflags" ; then
198         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
199         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
200 fi
201
202 if test -n "$cf_new_extra_cppflags" ; then
203         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
204         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
205 fi
206
207 AC_SUBST(EXTRA_CPPFLAGS)
208
209 ])dnl
210 dnl ---------------------------------------------------------------------------
211 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
212 dnl -------------
213 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
214 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
215 dnl but old versions (and some misinstalled ones) need that.  To make things
216 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
217 dnl the include-path).
218 AC_DEFUN([CF_ADD_INCDIR],
219 [
220 if test -n "$1" ; then
221   for cf_add_incdir in $1
222   do
223         while test $cf_add_incdir != /usr/include
224         do
225           if test -d $cf_add_incdir
226           then
227                 cf_have_incdir=no
228                 if test -n "$CFLAGS$CPPFLAGS" ; then
229                   # a loop is needed to ensure we can add subdirs of existing dirs
230                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
231                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
232                           cf_have_incdir=yes; break
233                         fi
234                   done
235                 fi
236
237                 if test "$cf_have_incdir" = no ; then
238                   if test "$cf_add_incdir" = /usr/local/include ; then
239                         if test "$GCC" = yes
240                         then
241                           cf_save_CPPFLAGS=$CPPFLAGS
242                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
243                           AC_TRY_COMPILE([#include <stdio.h>],
244                                   [printf("Hello")],
245                                   [],
246                                   [cf_have_incdir=yes])
247                           CPPFLAGS=$cf_save_CPPFLAGS
248                         fi
249                   fi
250                 fi
251
252                 if test "$cf_have_incdir" = no ; then
253                   CF_VERBOSE(adding $cf_add_incdir to include-path)
254                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
255
256                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
257                   test "$cf_top_incdir" = "$cf_add_incdir" && break
258                   cf_add_incdir="$cf_top_incdir"
259                 else
260                   break
261                 fi
262           fi
263         done
264   done
265 fi
266 ])dnl
267 dnl ---------------------------------------------------------------------------
268 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
269 dnl ----------
270 dnl Add a library, used to enforce consistency.
271 dnl
272 dnl $1 = library to add, without the "-l"
273 dnl $2 = variable to update (default $LIBS)
274 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
275 dnl ---------------------------------------------------------------------------
276 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
277 dnl -------------
278 dnl     Adds to the library-path
279 dnl
280 dnl     Some machines have trouble with multiple -L options.
281 dnl
282 dnl $1 is the (list of) directory(s) to add
283 dnl $2 is the optional name of the variable to update (default LDFLAGS)
284 dnl
285 AC_DEFUN([CF_ADD_LIBDIR],
286 [
287 if test -n "$1" ; then
288   for cf_add_libdir in $1
289   do
290     if test $cf_add_libdir = /usr/lib ; then
291       :
292     elif test -d $cf_add_libdir
293     then
294       cf_have_libdir=no
295       if test -n "$LDFLAGS$LIBS" ; then
296         # a loop is needed to ensure we can add subdirs of existing dirs
297         for cf_test_libdir in $LDFLAGS $LIBS ; do
298           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
299             cf_have_libdir=yes; break
300           fi
301         done
302       fi
303       if test "$cf_have_libdir" = no ; then
304         CF_VERBOSE(adding $cf_add_libdir to library-path)
305         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
306       fi
307     fi
308   done
309 fi
310 ])dnl
311 dnl ---------------------------------------------------------------------------
312 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
313 dnl -----------
314 dnl Add one or more libraries, used to enforce consistency.  Libraries are
315 dnl prepended to an existing list, since their dependencies are assumed to
316 dnl already exist in the list.
317 dnl
318 dnl $1 = libraries to add, with the "-l", etc.
319 dnl $2 = variable to update (default $LIBS)
320 AC_DEFUN([CF_ADD_LIBS],[
321 cf_add_libs="$1"
322 # Filter out duplicates - this happens with badly-designed ".pc" files...
323 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
324 do
325         for cf_add_2lib in $cf_add_libs
326         do
327                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
328                 then
329                         cf_add_1lib=
330                         break
331                 fi
332         done
333         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
334 done
335 ifelse($2,,LIBS,[$2])="$cf_add_libs"
336 ])dnl
337 dnl ---------------------------------------------------------------------------
338 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
339 dnl ------------------
340 dnl Append to a search-list for a nonstandard header/lib-file
341 dnl     $1 = the variable to return as result
342 dnl     $2 = the package name
343 dnl     $3 = the subdirectory, e.g., bin, include or lib
344 dnl $4 = the directory under which we will test for subdirectories
345 dnl $5 = a directory that we do not want $4 to match
346 AC_DEFUN([CF_ADD_SUBDIR_PATH],
347 [
348 test "x$4" != "x$5" && \
349 test -d "$4" && \
350 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
351         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
352         test -d $4/$3 &&          $1="[$]$1 $4/$3"
353         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
354         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
355         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
356         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
357 }
358 ])dnl
359 dnl ---------------------------------------------------------------------------
360 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
361 dnl --------------
362 dnl Allow user to disable a normally-on option.
363 AC_DEFUN([CF_ARG_DISABLE],
364 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
365 dnl ---------------------------------------------------------------------------
366 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
367 dnl -------------
368 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
369 dnl values.
370 dnl
371 dnl Parameters:
372 dnl $1 = option name
373 dnl $2 = help-string
374 dnl $3 = action to perform if option is not default
375 dnl $4 = action if perform if option is default
376 dnl $5 = default option value (either 'yes' or 'no')
377 AC_DEFUN([CF_ARG_OPTION],
378 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
379   if test "$enableval" != "$5" ; then
380 ifelse([$3],,[    :]dnl
381 ,[    $3]) ifelse([$4],,,[
382   else
383     $4])
384   fi],[enableval=$5 ifelse([$4],,,[
385   $4
386 ])dnl
387   ])])dnl
388 dnl ---------------------------------------------------------------------------
389 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
390 dnl -----------
391 dnl Check for suitable "ar" (archiver) options for updating an archive.
392 AC_DEFUN([CF_AR_FLAGS],[
393 AC_REQUIRE([CF_PROG_AR])
394
395 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
396         cf_cv_ar_flags=unknown
397         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
398         do
399
400                 # check if $ARFLAGS already contains this choice
401                 if test "x$ARFLAGS" != "x" ; then
402                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
403                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
404                                 cf_cv_ar_flags=
405                                 break
406                         fi
407                 fi
408
409                 rm -f conftest.$ac_cv_objext
410                 rm -f conftest.a
411
412                 cat >conftest.$ac_ext <<EOF
413 #line __oline__ "configure"
414 int     testdata[[3]] = { 123, 456, 789 };
415 EOF
416                 if AC_TRY_EVAL(ac_compile) ; then
417                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
418                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
419                         if test -f conftest.a ; then
420                                 cf_cv_ar_flags=$cf_ar_flags
421                                 break
422                         fi
423                 else
424                         CF_VERBOSE(cannot compile test-program)
425                         break
426                 fi
427         done
428         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
429 ])
430
431 if test -n "$ARFLAGS" ; then
432         if test -n "$cf_cv_ar_flags" ; then
433                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
434         fi
435 else
436         ARFLAGS=$cf_cv_ar_flags
437 fi
438
439 AC_SUBST(ARFLAGS)
440 ])
441 dnl ---------------------------------------------------------------------------
442 dnl CF_AWK_BIG_PRINTF version: 4 updated: 2011/10/30 17:09:50
443 dnl -----------------
444 dnl Check if awk can handle big strings using printf.  Some older versions of
445 dnl awk choke on large strings passed via "%s".
446 dnl
447 dnl $1 = desired string size
448 dnl $2 = variable to set with result
449 AC_DEFUN([CF_AWK_BIG_PRINTF],
450 [
451         case x$AWK in #(vi
452         x)
453                 eval $2=no
454                 ;;
455         *) #(vi
456                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
457                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
458                         eval $2=yes
459                 else
460                         eval $2=no
461                 fi
462                 ;;
463         esac
464 ])dnl
465 dnl ---------------------------------------------------------------------------
466 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
467 dnl ------------
468 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
469 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
470 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
471 dnl
472 dnl Treat the configuration-variable specially here, since we're directly
473 dnl substituting its value (i.e., 1/0).
474 dnl
475 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
476 AC_DEFUN([CF_BOOL_DECL],
477 [
478 AC_MSG_CHECKING(if we should include stdbool.h)
479
480 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
481         AC_TRY_COMPILE([],[bool foo = false],
482                 [cf_cv_header_stdbool_h=0],
483                 [AC_TRY_COMPILE([
484 #ifndef __BEOS__
485 #include <stdbool.h>
486 #endif
487 ],[bool foo = false],
488                         [cf_cv_header_stdbool_h=1],
489                         [cf_cv_header_stdbool_h=0])])])
490
491 if test "$cf_cv_header_stdbool_h" = 1
492 then    AC_MSG_RESULT(yes)
493 else    AC_MSG_RESULT(no)
494 fi
495
496 AC_MSG_CHECKING([for builtin bool type])
497
498 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
499         AC_TRY_COMPILE([
500 #include <stdio.h>
501 #include <sys/types.h>
502 ],[bool x = false],
503                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
504                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
505         ])
506
507 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
508 then    AC_MSG_RESULT(yes)
509 else    AC_MSG_RESULT(no)
510 fi
511 ])dnl
512 dnl ---------------------------------------------------------------------------
513 dnl CF_BOOL_SIZE version: 13 updated: 2013/04/13 18:03:21
514 dnl ------------
515 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
516 dnl Don't bother looking for bool.h, since it's been deprecated.
517 dnl
518 dnl If the current compiler is C rather than C++, we get the bool definition
519 dnl from <stdbool.h>.
520 AC_DEFUN([CF_BOOL_SIZE],
521 [
522 AC_MSG_CHECKING([for size of bool])
523 AC_CACHE_VAL(cf_cv_type_of_bool,[
524         rm -f cf_test.out
525         AC_TRY_RUN([
526 #include <stdlib.h>
527 #include <stdio.h>
528
529 #if defined(__cplusplus)
530
531 #ifdef HAVE_GXX_BUILTIN_H
532 #include <g++/builtin.h>
533 #elif HAVE_GPP_BUILTIN_H
534 #include <gpp/builtin.h>
535 #elif HAVE_BUILTIN_H
536 #include <builtin.h>
537 #endif
538
539 #else
540
541 #if $cf_cv_header_stdbool_h
542 #include <stdbool.h>
543 #endif
544
545 #endif
546
547 int main()
548 {
549         FILE *fp = fopen("cf_test.out", "w");
550         if (fp != 0) {
551                 bool x = true;
552                 if ((bool)(-x) >= 0)
553                         fputs("unsigned ", fp);
554                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
555                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
556                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
557                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
558                 fclose(fp);
559         }
560         ${cf_cv_main_return:-return}(0);
561 }
562                 ],
563                 [cf_cv_type_of_bool=`cat cf_test.out`
564                  if test -z "$cf_cv_type_of_bool"; then
565                    cf_cv_type_of_bool=unknown
566                  fi],
567                 [cf_cv_type_of_bool=unknown],
568                 [cf_cv_type_of_bool=unknown])
569         ])
570         rm -f cf_test.out
571 AC_MSG_RESULT($cf_cv_type_of_bool)
572 if test "$cf_cv_type_of_bool" = unknown ; then
573         case .$NCURSES_BOOL in #(vi
574         .auto|.) NCURSES_BOOL=unsigned;;
575         esac
576         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
577         cf_cv_type_of_bool=$NCURSES_BOOL
578 fi
579 ])dnl
580 dnl ---------------------------------------------------------------------------
581 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
582 dnl -----------
583 dnl If we're cross-compiling, allow the user to override the tools and their
584 dnl options.  The configure script is oriented toward identifying the host
585 dnl compiler, etc., but we need a build compiler to generate parts of the
586 dnl source.
587 dnl
588 dnl $1 = default for $CPPFLAGS
589 dnl $2 = default for $LIBS
590 AC_DEFUN([CF_BUILD_CC],[
591 CF_ACVERSION_CHECK(2.52,,
592         [AC_REQUIRE([CF_PROG_EXT])])
593 if test "$cross_compiling" = yes ; then
594
595         # defaults that we might want to override
596         : ${BUILD_CFLAGS:=''}
597         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
598         : ${BUILD_LDFLAGS:=''}
599         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
600         : ${BUILD_EXEEXT:='$x'}
601         : ${BUILD_OBJEXT:='o'}
602
603         AC_ARG_WITH(build-cc,
604                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
605                 [BUILD_CC="$withval"],
606                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
607         AC_MSG_CHECKING(for native build C compiler)
608         AC_MSG_RESULT($BUILD_CC)
609
610         AC_MSG_CHECKING(for native build C preprocessor)
611         AC_ARG_WITH(build-cpp,
612                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
613                 [BUILD_CPP="$withval"],
614                 [BUILD_CPP='${BUILD_CC} -E'])
615         AC_MSG_RESULT($BUILD_CPP)
616
617         AC_MSG_CHECKING(for native build C flags)
618         AC_ARG_WITH(build-cflags,
619                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
620                 [BUILD_CFLAGS="$withval"])
621         AC_MSG_RESULT($BUILD_CFLAGS)
622
623         AC_MSG_CHECKING(for native build C preprocessor-flags)
624         AC_ARG_WITH(build-cppflags,
625                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
626                 [BUILD_CPPFLAGS="$withval"])
627         AC_MSG_RESULT($BUILD_CPPFLAGS)
628
629         AC_MSG_CHECKING(for native build linker-flags)
630         AC_ARG_WITH(build-ldflags,
631                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
632                 [BUILD_LDFLAGS="$withval"])
633         AC_MSG_RESULT($BUILD_LDFLAGS)
634
635         AC_MSG_CHECKING(for native build linker-libraries)
636         AC_ARG_WITH(build-libs,
637                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
638                 [BUILD_LIBS="$withval"])
639         AC_MSG_RESULT($BUILD_LIBS)
640
641         # this assumes we're on Unix.
642         BUILD_EXEEXT=
643         BUILD_OBJEXT=o
644
645         : ${BUILD_CC:='${CC}'}
646
647         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
648                 AC_MSG_ERROR([Cross-build requires two compilers.
649 Use --with-build-cc to specify the native compiler.])
650         fi
651
652 else
653         : ${BUILD_CC:='${CC}'}
654         : ${BUILD_CPP:='${CPP}'}
655         : ${BUILD_CFLAGS:='${CFLAGS}'}
656         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
657         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
658         : ${BUILD_LIBS:='${LIBS}'}
659         : ${BUILD_EXEEXT:='$x'}
660         : ${BUILD_OBJEXT:='o'}
661 fi
662
663 AC_SUBST(BUILD_CC)
664 AC_SUBST(BUILD_CPP)
665 AC_SUBST(BUILD_CFLAGS)
666 AC_SUBST(BUILD_CPPFLAGS)
667 AC_SUBST(BUILD_LDFLAGS)
668 AC_SUBST(BUILD_LIBS)
669 AC_SUBST(BUILD_EXEEXT)
670 AC_SUBST(BUILD_OBJEXT)
671 ])dnl
672 dnl ---------------------------------------------------------------------------
673 dnl CF_CC_ENV_FLAGS version: 1 updated: 2012/10/03 05:25:49
674 dnl ---------------
675 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
676 dnl into CC.  This will not help with broken scripts that wrap the compiler with
677 dnl options, but eliminates a more common category of user confusion.
678 AC_DEFUN([CF_CC_ENV_FLAGS],
679 [
680 # This should have been defined by AC_PROG_CC
681 : ${CC:=cc}
682
683 AC_MSG_CHECKING(\$CC variable)
684 case "$CC" in #(vi
685 *[[\ \  ]]-[[IUD]]*)
686         AC_MSG_RESULT(broken)
687         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
688         # humor him...
689         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
690         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
691         CF_ADD_CFLAGS($cf_flags)
692         ;;
693 *)
694         AC_MSG_RESULT(ok)
695         ;;
696 esac
697 ])dnl
698 dnl ---------------------------------------------------------------------------
699 dnl CF_CFG_DEFAULTS version: 10 updated: 2013/09/07 13:54:05
700 dnl ---------------
701 dnl Determine the default configuration into which we'll install ncurses.  This
702 dnl can be overridden by the user's command-line options.  There's two items to
703 dnl look for:
704 dnl     1. the prefix (e.g., /usr)
705 dnl     2. the header files (e.g., /usr/include/ncurses)
706 dnl We'll look for a previous installation of ncurses and use the same defaults.
707 dnl
708 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
709 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
710 dnl programs from a vendor's.
711 AC_DEFUN([CF_CFG_DEFAULTS],
712 [
713 AC_MSG_CHECKING(for prefix)
714 if test "x$prefix" = "xNONE" ; then
715         case "$cf_cv_system_name" in
716                 # non-vendor systems don't have a conflict
717         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
718                 prefix=/usr
719                 ;;
720         *)      prefix=$ac_default_prefix
721                 ;;
722         esac
723 fi
724 AC_MSG_RESULT($prefix)
725
726 if test "x$prefix" = "xNONE" ; then
727 AC_MSG_CHECKING(for default include-directory)
728 test -n "$verbose" && echo 1>&AC_FD_MSG
729 for cf_symbol in \
730         $includedir \
731         $includedir/ncurses \
732         $prefix/include \
733         $prefix/include/ncurses \
734         /usr/local/include \
735         /usr/local/include/ncurses \
736         /usr/include \
737         /usr/include/ncurses
738 do
739         cf_dir=`eval echo $cf_symbol`
740         if test -f $cf_dir/curses.h ; then
741         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
742                 includedir="$cf_symbol"
743                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
744                 break
745         fi
746         fi
747         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
748 done
749 AC_MSG_RESULT($includedir)
750 fi
751 ])dnl
752 dnl ---------------------------------------------------------------------------
753 dnl CF_CGETENT version: 5 updated: 2012/10/06 17:56:13
754 dnl ----------
755 dnl Check if the terminal-capability database functions are available.  If not,
756 dnl ncurses has a much-reduced version.
757 AC_DEFUN([CF_CGETENT],[
758 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
759 AC_TRY_LINK([
760 #include <stdlib.h>],[
761         char temp[128];
762         char *buf = temp;
763         char *db_array = temp;
764         cgetent(&buf, &db_array, "vt100");
765         cgetcap(buf, "tc", '=');
766         cgetmatch(buf, "tc");
767         ],
768         [cf_cv_cgetent=yes],
769         [cf_cv_cgetent=no])
770 ])
771
772 if test "$cf_cv_cgetent" = yes
773 then
774         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
775 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
776 AC_TRY_LINK([
777 #include <stdlib.h>],[
778         char temp[128];
779         char *buf = temp;
780 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
781         const char *db_array = temp;
782         cgetent(&buf, &db_array, "vt100");
783 #endif
784         cgetcap(buf, "tc", '=');
785         cgetmatch(buf, "tc");
786         ],
787         [cf_cv_cgetent_const=yes],
788         [cf_cv_cgetent_const=no])
789 ])
790         if test "$cf_cv_cgetent_const" = yes
791         then
792                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
793         fi
794 fi
795 ])dnl
796 dnl ---------------------------------------------------------------------------
797 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
798 dnl --------------
799 dnl Check if we're accidentally using a cache from a different machine.
800 dnl Derive the system name, as a check for reusing the autoconf cache.
801 dnl
802 dnl If we've packaged config.guess and config.sub, run that (since it does a
803 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
804 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
805 dnl which is useful in cross-compiles.
806 dnl
807 dnl Note: we would use $ac_config_sub, but that is one of the places where
808 dnl autoconf 2.5x broke compatibility with autoconf 2.13
809 AC_DEFUN([CF_CHECK_CACHE],
810 [
811 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
812         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
813         system_name="$host_os"
814 else
815         system_name="`(uname -s -r) 2>/dev/null`"
816         if test -z "$system_name" ; then
817                 system_name="`(hostname) 2>/dev/null`"
818         fi
819 fi
820 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
821 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
822
823 test -z "$system_name" && system_name="$cf_cv_system_name"
824 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
825
826 if test ".$system_name" != ".$cf_cv_system_name" ; then
827         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
828         AC_MSG_ERROR("Please remove config.cache and try again.")
829 fi
830 ])dnl
831 dnl ---------------------------------------------------------------------------
832 dnl CF_CHECK_ERRNO version: 11 updated: 2010/05/26 05:38:42
833 dnl --------------
834 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
835 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
836 dnl ourselves.
837 dnl
838 dnl $1 = the name to check
839 dnl $2 = the assumed type
840 AC_DEFUN([CF_CHECK_ERRNO],
841 [
842 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
843     AC_TRY_COMPILE([
844 #ifdef HAVE_STDLIB_H
845 #include <stdlib.h>
846 #endif
847 #include <stdio.h>
848 #include <sys/types.h>
849 #include <errno.h> ],
850     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
851     [cf_cv_dcl_$1=yes],
852     [cf_cv_dcl_$1=no])
853 ])
854
855 if test "$cf_cv_dcl_$1" = no ; then
856     CF_UPPER(cf_result,decl_$1)
857     AC_DEFINE_UNQUOTED($cf_result)
858 fi
859
860 # It's possible (for near-UNIX clones) that the data doesn't exist
861 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
862 ])dnl
863 dnl ---------------------------------------------------------------------------
864 dnl CF_CHECK_EXTERN_DATA version: 3 updated: 2001/12/30 18:03:23
865 dnl --------------------
866 dnl Check for existence of external data in the current set of libraries.  If
867 dnl we can modify it, it's real enough.
868 dnl $1 = the name to check
869 dnl $2 = its type
870 AC_DEFUN([CF_CHECK_EXTERN_DATA],
871 [
872 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
873     AC_TRY_LINK([
874 #undef $1
875 extern $2 $1;
876 ],
877     [$1 = 2],
878     [cf_cv_have_$1=yes],
879     [cf_cv_have_$1=no])
880 ])
881
882 if test "$cf_cv_have_$1" = yes ; then
883     CF_UPPER(cf_result,have_$1)
884     AC_DEFINE_UNQUOTED($cf_result)
885 fi
886
887 ])dnl
888 dnl ---------------------------------------------------------------------------
889 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
890 dnl -------------------
891 dnl Check if GPM is already linked with curses.  If so - and if the linkage
892 dnl is not "weak" - warn about this because it can create problems linking
893 dnl applications with ncurses.
894 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
895 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
896
897 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
898 cf_cv_check_gpm_wgetch=unknown
899 if test "$cross_compiling" != yes ; then
900
901 cat >conftest.$ac_ext <<CF_EOF
902 #include <gpm.h>
903 int main()
904 {
905         Gpm_Wgetch();
906         ${cf_cv_main_return:-return}(0);
907 }
908 CF_EOF
909
910         cf_save_LIBS="$LIBS"
911         # This only works if we can look at the symbol table.  If a shared
912         # library is stripped for install, we cannot use that.  So we're forced
913         # to rely on the static library, noting that some packagers may not
914         # include it.
915         LIBS="-static -lgpm -dynamic $LIBS"
916         if AC_TRY_EVAL(ac_compile) ; then
917                 if AC_TRY_EVAL(ac_link) ; then
918                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
919                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
920                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
921                 fi
922         fi
923         rm -rf conftest*
924         LIBS="$cf_save_LIBS"
925 fi
926 ])
927
928 if test "$cf_cv_check_gpm_wgetch" != yes ; then
929         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
930 fi
931 ])])dnl
932 dnl ---------------------------------------------------------------------------
933 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
934 dnl ------------------------
935 dnl Show the version of libtool
936 dnl
937 dnl Save the version in a cache variable - this is not entirely a good thing,
938 dnl but the version string from libtool is very ugly, and for bug reports it
939 dnl might be useful to have the original string.
940 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
941 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
942 then
943         AC_MSG_CHECKING(version of $LIBTOOL)
944         CF_LIBTOOL_VERSION
945         AC_MSG_RESULT($cf_cv_libtool_version)
946         if test -z "$cf_cv_libtool_version" ; then
947                 AC_MSG_ERROR(This is not GNU libtool)
948         fi
949 else
950         AC_MSG_ERROR(GNU libtool has not been found)
951 fi
952 ])dnl
953 dnl ---------------------------------------------------------------------------
954 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
955 dnl ----------------
956 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
957 AC_DEFUN([CF_CHECK_WCHAR_H],[
958 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
959 AC_TRY_COMPILE(
960 [
961 #include <stdlib.h>
962 #include <wchar.h>
963 ],[
964         wint_t foo = 0;
965         int bar = iswpunct(foo)],
966         [cf_cv_wchar_h_okay=yes],
967         [cf_cv_wchar_h_okay=no])])
968
969 if test $cf_cv_wchar_h_okay = no
970 then
971         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
972 fi
973 ])dnl
974 dnl ---------------------------------------------------------------------------
975 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
976 dnl -----------------
977 dnl Check if the given compiler is really clang.  clang's C driver defines
978 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
979 dnl not ignore some gcc options.
980 dnl
981 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
982 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
983 dnl the wrappers for gcc and g++ warnings.
984 dnl
985 dnl $1 = GCC (default) or GXX
986 dnl $2 = CLANG_COMPILER (default)
987 dnl $3 = CFLAGS (default) or CXXFLAGS
988 AC_DEFUN([CF_CLANG_COMPILER],[
989 ifelse([$2],,CLANG_COMPILER,[$2])=no
990
991 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
992         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
993         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
994         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
995         AC_TRY_COMPILE([],[
996 #ifdef __clang__
997 #else
998 make an error
999 #endif
1000 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1001 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1002 ],[])
1003         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1004         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1005 fi
1006 ])
1007 dnl ---------------------------------------------------------------------------
1008 dnl CF_CPP_PARAM_INIT version: 6 updated: 2012/10/06 17:56:13
1009 dnl -----------------
1010 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1011 dnl is a late feature for the standard and is not in some recent compilers
1012 dnl (1999/9/11).
1013 AC_DEFUN([CF_CPP_PARAM_INIT],
1014 [
1015 if test -n "$CXX"; then
1016 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1017         AC_LANG_SAVE
1018         AC_LANG_CPLUSPLUS
1019         AC_TRY_RUN([
1020 class TEST {
1021 private:
1022         int value;
1023 public:
1024         TEST(int x = 1);
1025         ~TEST();
1026 };
1027
1028 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1029 {
1030         value = x;
1031 }
1032 int main() { }
1033 ],
1034         [cf_cv_cpp_param_init=yes],
1035         [cf_cv_cpp_param_init=no],
1036         [cf_cv_cpp_param_init=unknown])
1037         AC_LANG_RESTORE
1038 ])
1039 fi
1040 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1041 ])dnl
1042 dnl ---------------------------------------------------------------------------
1043 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1044 dnl ------------------
1045 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1046 dnl not be supported in g++ before 3.0
1047 AC_DEFUN([CF_CPP_STATIC_CAST],
1048 [
1049 if test -n "$CXX"; then
1050
1051 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1052         AC_LANG_SAVE
1053         AC_LANG_CPLUSPLUS
1054
1055         AC_TRY_COMPILE([
1056 class NCursesPanel
1057 {
1058 public:
1059   NCursesPanel(int nlines,
1060                int ncols,
1061                int begin_y = 0,
1062                int begin_x = 0)
1063   {
1064   }
1065   NCursesPanel();
1066   ~NCursesPanel();
1067 };
1068
1069 template<class T> class NCursesUserPanel : public NCursesPanel
1070 {
1071 public:
1072   NCursesUserPanel (int nlines,
1073                     int ncols,
1074                     int begin_y = 0,
1075                     int begin_x = 0,
1076                     const T* p_UserData = static_cast<T*>(0))
1077     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1078   {
1079   };
1080   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1081   {
1082   };
1083
1084   virtual ~NCursesUserPanel() {};
1085 };
1086 ],[
1087         const char* p_UserData = static_cast<char*>(0)],
1088         [cf_cv_cpp_static_cast=yes],
1089         [cf_cv_cpp_static_cast=no])
1090
1091         AC_LANG_RESTORE
1092 ])
1093
1094 fi
1095
1096 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1097 ])dnl
1098 dnl ---------------------------------------------------------------------------
1099 dnl CF_CXX_AR_FLAGS version: 1 updated: 2011/10/29 08:35:34
1100 dnl ---------------
1101 dnl Setup special archiver flags for given compilers.
1102 AC_DEFUN([CF_CXX_AR_FLAGS],[
1103         CXX_AR='$(AR)'
1104         CXX_ARFLAGS='$(ARFLAGS)'
1105         case $cf_cv_system_name in #(vi
1106         irix*) #(vi
1107             if test "$GXX" != yes ; then
1108                 CXX_AR='$(CXX)'
1109                 CXX_ARFLAGS='-ar -o'
1110             fi
1111             ;;
1112         sco3.2v5*) #(vi
1113             CXXLDFLAGS="-u main"
1114             ;;
1115         solaris2*)
1116             if test "$GXX" != yes ; then
1117                 CXX_AR='$(CXX)'
1118                 CXX_ARFLAGS='-xar -o'
1119             fi
1120             ;;
1121         esac
1122         AC_SUBST(CXXLDFLAGS)
1123         AC_SUBST(CXX_AR)
1124         AC_SUBST(CXX_ARFLAGS)
1125 ])dnl
1126 dnl ---------------------------------------------------------------------------
1127 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1128 dnl -------------------------
1129 dnl For c++, check if iostream uses "std::" namespace.
1130 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1131 AC_CHECK_HEADERS(iostream)
1132 if test x"$ac_cv_header_iostream" = xyes ; then
1133         AC_MSG_CHECKING(if iostream uses std-namespace)
1134         AC_TRY_COMPILE([
1135 #include <iostream>
1136 using std::endl;
1137 using std::cerr;],[
1138 cerr << "testing" << endl;
1139 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1140         AC_MSG_RESULT($cf_iostream_namespace)
1141         if test "$cf_iostream_namespace" = yes ; then
1142                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1143         fi
1144 fi
1145 ])dnl
1146 dnl ---------------------------------------------------------------------------
1147 dnl CF_C_INLINE version: 4 updated: 2012/06/16 14:55:39
1148 dnl -----------
1149 dnl Check if the C compiler supports "inline".
1150 dnl $1 is the name of a shell variable to set if inline is supported
1151 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1152 AC_DEFUN([CF_C_INLINE],[
1153 AC_C_INLINE
1154 $1=
1155 if test "$ac_cv_c_inline" != no ; then
1156   $1=inline
1157   if test "$INTEL_COMPILER" = yes
1158   then
1159     :
1160   elif test "$CLANG_COMPILER" = yes
1161   then
1162     :
1163   elif test "$GCC" = yes
1164   then
1165     AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1166       cf_save_CFLAGS=$CFLAGS
1167       CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1168       AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1169       [${cf_cv_main_return:-return} foo()],
1170       [cf_cv_gcc_inline=yes],
1171       [cf_cv_gcc_inline=no])
1172       CFLAGS=$cf_save_CFLAGS
1173     ])
1174     if test "$cf_cv_gcc_inline" = yes ; then
1175         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1176     fi
1177   fi
1178 fi
1179 AC_SUBST($1)
1180 ])dnl
1181 dnl ---------------------------------------------------------------------------
1182 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1183 dnl ----------
1184 dnl "dirname" is not portable, so we fake it with a shell script.
1185 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1186 dnl ---------------------------------------------------------------------------
1187 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1188 dnl ---------------
1189 AC_DEFUN([CF_DIRS_TO_MAKE],
1190 [
1191 DIRS_TO_MAKE="lib"
1192 for cf_item in $cf_list_models
1193 do
1194         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1195         for cf_item2 in $DIRS_TO_MAKE
1196         do
1197                 test $cf_item2 = $cf_subdir && break
1198         done
1199         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1200 done
1201 for cf_dir in $DIRS_TO_MAKE
1202 do
1203         test ! -d $cf_dir && mkdir $cf_dir
1204 done
1205 AC_SUBST(DIRS_TO_MAKE)
1206 ])dnl
1207 dnl ---------------------------------------------------------------------------
1208 dnl CF_DISABLE_ECHO version: 12 updated: 2012/10/06 16:30:28
1209 dnl ---------------
1210 dnl You can always use "make -n" to see the actual options, but it's hard to
1211 dnl pick out/analyze warning messages when the compile-line is long.
1212 dnl
1213 dnl Sets:
1214 dnl     ECHO_LT - symbol to control if libtool is verbose
1215 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1216 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1217 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1218 dnl     ECHO_CC - symbol to put before any "cc" line
1219 dnl
1220 AC_DEFUN([CF_DISABLE_ECHO],[
1221 AC_MSG_CHECKING(if you want to see long compiling messages)
1222 CF_ARG_DISABLE(echo,
1223         [  --disable-echo          do not display "compiling" commands],
1224         [
1225     ECHO_LT='--silent'
1226     ECHO_LD='@echo linking [$]@;'
1227     RULE_CC='@echo compiling [$]<'
1228     SHOW_CC='@echo compiling [$]@'
1229     ECHO_CC='@'
1230 ],[
1231     ECHO_LT=''
1232     ECHO_LD=''
1233     RULE_CC=''
1234     SHOW_CC=''
1235     ECHO_CC=''
1236 ])
1237 AC_MSG_RESULT($enableval)
1238 AC_SUBST(ECHO_LT)
1239 AC_SUBST(ECHO_LD)
1240 AC_SUBST(RULE_CC)
1241 AC_SUBST(SHOW_CC)
1242 AC_SUBST(ECHO_CC)
1243 ])dnl
1244 dnl ---------------------------------------------------------------------------
1245 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1246 dnl ------------------------
1247 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1248 AC_MSG_CHECKING(if we want to use GNAT projects)
1249 CF_ARG_DISABLE(gnat-projects,
1250         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1251         [enable_gnat_projects=no],
1252         [enable_gnat_projects=yes])
1253 AC_MSG_RESULT($enable_gnat_projects)
1254 ])dnl
1255 dnl ---------------------------------------------------------------------------
1256 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1257 dnl ----------------
1258 dnl Combine no-leak checks with the libraries or tools that are used for the
1259 dnl checks.
1260 AC_DEFUN([CF_DISABLE_LEAKS],[
1261
1262 AC_REQUIRE([CF_WITH_DMALLOC])
1263 AC_REQUIRE([CF_WITH_DBMALLOC])
1264 AC_REQUIRE([CF_WITH_VALGRIND])
1265
1266 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1267 AC_ARG_ENABLE(leaks,
1268         [  --disable-leaks         test: free permanent memory, analyze leaks],
1269         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1270         : ${with_no_leaks:=no})
1271 AC_MSG_RESULT($with_no_leaks)
1272
1273 if test "$with_no_leaks" = yes ; then
1274         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1275         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1276 fi
1277 ])dnl
1278 dnl ---------------------------------------------------------------------------
1279 dnl CF_DISABLE_LIBTOOL_VERSION version: 2 updated: 2014/11/15 19:05:29
1280 dnl --------------------------
1281 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1282 dnl the older "-version-info" feature.  The newer feature allows us to use
1283 dnl version numbering on shared libraries which make them compatible with
1284 dnl various systems.
1285 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1286 [
1287 AC_MSG_CHECKING(if libtool -version-number should be used)
1288 CF_ARG_DISABLE(libtool-version,
1289         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1290         [cf_libtool_version=no],
1291         [cf_libtool_version=yes])
1292 AC_MSG_RESULT($cf_libtool_version)
1293
1294 if test "$cf_libtool_version" = yes ; then
1295         LIBTOOL_VERSION="-version-number"
1296 else
1297         LIBTOOL_VERSION="-version-info"
1298         case "x$VERSION" in #(vi
1299         x) #(vi
1300                 AC_MSG_WARN(VERSION was not set)
1301                 ;;
1302         x*.*.*)
1303                 ABI_VERSION="$VERSION"
1304                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1305                 ;;
1306         x*:*:*)
1307                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1308                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1309                 ;;
1310         *)
1311                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1312                 ;;
1313         esac
1314 fi
1315
1316 AC_SUBST(ABI_VERSION)
1317 AC_SUBST(LIBTOOL_VERSION)
1318 ])dnl
1319 dnl ---------------------------------------------------------------------------
1320 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1321 dnl ---------------------
1322 dnl The rpath-hack makes it simpler to build programs, particularly with the
1323 dnl *BSD ports which may have essential libraries in unusual places.  But it
1324 dnl can interfere with building an executable for the base system.  Use this
1325 dnl option in that case.
1326 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1327 [
1328 AC_MSG_CHECKING(if rpath-hack should be disabled)
1329 CF_ARG_DISABLE(rpath-hack,
1330         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1331         [cf_disable_rpath_hack=yes],
1332         [cf_disable_rpath_hack=no])
1333 AC_MSG_RESULT($cf_disable_rpath_hack)
1334 if test "$cf_disable_rpath_hack" = no ; then
1335         CF_RPATH_HACK
1336 fi
1337 ])
1338 dnl ---------------------------------------------------------------------------
1339 dnl CF_ENABLE_PC_FILES version: 11 updated: 2015/01/10 17:03:43
1340 dnl ------------------
1341 dnl This is the "--enable-pc-files" option, which is available if there is a
1342 dnl pkg-config configuration on the local machine.
1343 AC_DEFUN([CF_ENABLE_PC_FILES],[
1344 AC_REQUIRE([CF_PKG_CONFIG])
1345 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1346
1347 if test "x$PKG_CONFIG" != xnone
1348 then
1349         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1350 else
1351         AC_MSG_CHECKING(if we should install .pc files)
1352 fi
1353
1354 AC_ARG_ENABLE(pc-files,
1355         [  --enable-pc-files       generate and install .pc files for pkg-config],
1356         [enable_pc_files=$enableval],
1357         [enable_pc_files=no])
1358 AC_MSG_RESULT($enable_pc_files)
1359
1360 if test "x$enable_pc_files" != xno
1361 then
1362         case "x$PKG_CONFIG_LIBDIR" in #(vi
1363         xno|xyes) #(vi
1364                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1365                 MAKE_PC_FILES="#"
1366                 ;;
1367         *)
1368                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1369                 MAKE_PC_FILES=
1370                 ;;
1371         esac
1372 else
1373         MAKE_PC_FILES="#"
1374 fi
1375 AC_SUBST(MAKE_PC_FILES)
1376 ])dnl
1377 dnl ---------------------------------------------------------------------------
1378 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1379 dnl ---------------
1380 dnl Check if the rpath option should be used, setting cache variable
1381 dnl cf_cv_enable_rpath if so.
1382 AC_DEFUN([CF_ENABLE_RPATH],
1383 [
1384 AC_MSG_CHECKING(if rpath option should be used)
1385 AC_ARG_ENABLE(rpath,
1386 [  --enable-rpath          use rpath option when generating shared libraries],
1387 [cf_cv_enable_rpath=$enableval],
1388 [cf_cv_enable_rpath=no])
1389 AC_MSG_RESULT($cf_cv_enable_rpath)
1390 ])dnl
1391 dnl ---------------------------------------------------------------------------
1392 dnl CF_ENABLE_STRING_HACKS version: 3 updated: 2013/01/26 16:26:12
1393 dnl ----------------------
1394 dnl On a few platforms, the compiler and/or loader nags with untruthful
1395 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1396 dnl and implying that most uses of the recommended alternatives are correct.
1397 dnl
1398 dnl Factually speaking, no one has actually counted the number of uses of these
1399 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1400 dnl instances are meaningless compared to the hundreds of millions of lines of
1401 dnl existing C code.
1402 dnl
1403 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1404 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1405 dnl standard - but evolved through phases, and older implementations are likely
1406 dnl to yield surprising results, as documented in manpages on various systems.
1407 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1408 [
1409 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1410 AC_ARG_ENABLE(string-hacks,
1411         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1412         [with_string_hacks=$enableval],
1413         [with_string_hacks=no])
1414 AC_MSG_RESULT($with_string_hacks)
1415
1416 if test "x$with_string_hacks" = "xyes"; then
1417         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1418         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1419         AC_CHECK_FUNCS( strlcat strlcpy snprintf )
1420 fi
1421 ])dnl
1422 dnl ---------------------------------------------------------------------------
1423 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1424 dnl --------
1425 dnl Check if 'errno' is declared in <errno.h>
1426 AC_DEFUN([CF_ERRNO],
1427 [
1428 CF_CHECK_ERRNO(errno)
1429 ])dnl
1430 dnl ---------------------------------------------------------------------------
1431 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1432 dnl ---------------
1433 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1434 dnl math.h and builtin.h, only for ncurses
1435 AC_DEFUN([CF_ETIP_DEFINES],
1436 [
1437 AC_MSG_CHECKING(for special defines needed for etip.h)
1438 cf_save_CXXFLAGS="$CXXFLAGS"
1439 cf_result="none"
1440
1441 # etip.h includes ncurses.h which includes ncurses_dll.h
1442 # But ncurses_dll.h is generated - fix here.
1443 test -d include || mkdir include
1444 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1445
1446 for cf_math in "" MATH_H
1447 do
1448 for cf_excp in "" MATH_EXCEPTION
1449 do
1450         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1451         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1452         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1453 AC_TRY_COMPILE([
1454 #include <etip.h.in>
1455 ],[],[
1456         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1457         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1458         cf_result="$cf_math $cf_excp"
1459         break 2
1460 ],[])
1461 done
1462 done
1463 AC_MSG_RESULT($cf_result)
1464 CXXFLAGS="$cf_save_CXXFLAGS"
1465 ])
1466 dnl ---------------------------------------------------------------------------
1467 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1468 dnl ---------------
1469 dnl Find a library (specifically the linkage used in the code fragment),
1470 dnl searching for it if it is not already in the library path.
1471 dnl See also CF_ADD_SEARCHPATH.
1472 dnl
1473 dnl Parameters (4-on are optional):
1474 dnl     $1 = headers for library entrypoint
1475 dnl     $2 = code fragment for library entrypoint
1476 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1477 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1478 dnl     $5 = action to perform if not successful
1479 dnl     $6 = module name, if not the same as the library name
1480 dnl     $7 = extra libraries
1481 dnl
1482 dnl Sets these variables:
1483 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1484 dnl     $cf_cv_header_path_$3 - include-directory if needed
1485 dnl     $cf_cv_library_path_$3 - library-directory if needed
1486 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1487 AC_DEFUN([CF_FIND_LINKAGE],[
1488
1489 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1490 # will be set on completion of the AC_TRY_LINK below.
1491 cf_cv_header_path_$3=
1492 cf_cv_library_path_$3=
1493
1494 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1495
1496 cf_save_LIBS="$LIBS"
1497
1498 AC_TRY_LINK([$1],[$2],[
1499         cf_cv_find_linkage_$3=yes
1500         cf_cv_header_path_$3=/usr/include
1501         cf_cv_library_path_$3=/usr/lib
1502 ],[
1503
1504 LIBS="-l$3 $7 $cf_save_LIBS"
1505
1506 AC_TRY_LINK([$1],[$2],[
1507         cf_cv_find_linkage_$3=yes
1508         cf_cv_header_path_$3=/usr/include
1509         cf_cv_library_path_$3=/usr/lib
1510         cf_cv_library_file_$3="-l$3"
1511 ],[
1512         cf_cv_find_linkage_$3=no
1513         LIBS="$cf_save_LIBS"
1514
1515     CF_VERBOSE(find linkage for $3 library)
1516     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1517
1518     cf_save_CPPFLAGS="$CPPFLAGS"
1519     cf_test_CPPFLAGS="$CPPFLAGS"
1520
1521     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1522     for cf_cv_header_path_$3 in $cf_search
1523     do
1524       if test -d $cf_cv_header_path_$3 ; then
1525         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1526         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1527         AC_TRY_COMPILE([$1],[$2],[
1528             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1529             cf_cv_find_linkage_$3=maybe
1530             cf_test_CPPFLAGS="$CPPFLAGS"
1531             break],[
1532             CPPFLAGS="$cf_save_CPPFLAGS"
1533             ])
1534       fi
1535     done
1536
1537     if test "$cf_cv_find_linkage_$3" = maybe ; then
1538
1539       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1540
1541       cf_save_LIBS="$LIBS"
1542       cf_save_LDFLAGS="$LDFLAGS"
1543
1544       ifelse([$6],,,[
1545         CPPFLAGS="$cf_test_CPPFLAGS"
1546         LIBS="-l$3 $7 $cf_save_LIBS"
1547         AC_TRY_LINK([$1],[$2],[
1548             CF_VERBOSE(... found $3 library in system)
1549             cf_cv_find_linkage_$3=yes])
1550             CPPFLAGS="$cf_save_CPPFLAGS"
1551             LIBS="$cf_save_LIBS"
1552             ])
1553
1554       if test "$cf_cv_find_linkage_$3" != yes ; then
1555         CF_LIBRARY_PATH(cf_search,$3)
1556         for cf_cv_library_path_$3 in $cf_search
1557         do
1558           if test -d $cf_cv_library_path_$3 ; then
1559             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1560             CPPFLAGS="$cf_test_CPPFLAGS"
1561             LIBS="-l$3 $7 $cf_save_LIBS"
1562             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1563             AC_TRY_LINK([$1],[$2],[
1564                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1565                 cf_cv_find_linkage_$3=yes
1566                 cf_cv_library_file_$3="-l$3"
1567                 break],[
1568                 CPPFLAGS="$cf_save_CPPFLAGS"
1569                 LIBS="$cf_save_LIBS"
1570                 LDFLAGS="$cf_save_LDFLAGS"
1571                 ])
1572           fi
1573         done
1574         CPPFLAGS="$cf_save_CPPFLAGS"
1575         LDFLAGS="$cf_save_LDFLAGS"
1576       fi
1577
1578     else
1579       cf_cv_find_linkage_$3=no
1580     fi
1581     ],$7)
1582 ])
1583
1584 LIBS="$cf_save_LIBS"
1585
1586 if test "$cf_cv_find_linkage_$3" = yes ; then
1587 ifelse([$4],,[
1588         CF_ADD_INCDIR($cf_cv_header_path_$3)
1589         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1590         CF_ADD_LIB($3)
1591 ],[$4])
1592 else
1593 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1594 fi
1595 ])dnl
1596 dnl ---------------------------------------------------------------------------
1597 dnl CF_FIND_SUB_INCDIR version: 1 updated: 2014/04/12 16:47:01
1598 dnl ------------------
1599 dnl Find an include-directory with the given leaf-name.  This is useful for
1600 dnl example with FreeBSD ports, which use this convention to distinguish
1601 dnl different versions of the same port.
1602 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1603         CF_SUBDIR_PATH(cf_search,$1,include)
1604         for cf_item in $cf_search
1605         do
1606                 case $cf_item in #(vi
1607                 */$1)
1608                         CF_ADD_INCDIR($cf_item)
1609                         ;;
1610                 esac
1611         done
1612 ])dnl
1613 dnl ---------------------------------------------------------------------------
1614 dnl CF_FIND_SUB_LIBDIR version: 1 updated: 2014/04/12 16:47:01
1615 dnl ------------------
1616 dnl Find a library-directory with the given leaf-name.  This is useful for
1617 dnl example with FreeBSD ports, which use this convention to distinguish
1618 dnl different versions of the same port.
1619 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1620         CF_SUBDIR_PATH(cf_search,$1,lib)
1621         for cf_item in $cf_search
1622         do
1623                 case $cf_item in #(vi
1624                 */$1)
1625                         CF_ADD_LIBDIR($cf_item)
1626                         ;;
1627                 esac
1628         done
1629 ])dnl
1630 dnl ---------------------------------------------------------------------------
1631 dnl CF_FIXUP_ADAFLAGS version: 1 updated: 2012/03/31 18:48:10
1632 dnl -----------------
1633 dnl make ADAFLAGS consistent with CFLAGS
1634 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1635         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1636         case "$CFLAGS" in
1637         *-g*)
1638                 CF_ADD_ADAFLAGS(-g)
1639                 ;;
1640         esac
1641         case "$CFLAGS" in
1642         *-O*)
1643                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1644                 CF_ADD_ADAFLAGS($cf_O_flag)
1645                 ;;
1646         esac
1647         AC_MSG_RESULT($ADAFLAGS)
1648 ])dnl
1649 dnl ---------------------------------------------------------------------------
1650 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1651 dnl --------------
1652 dnl Forget that we saw the given tool.
1653 AC_DEFUN([CF_FORGET_TOOL],[
1654 unset ac_cv_prog_ac_ct_$1
1655 unset ac_ct_$1
1656 unset $1
1657 ])dnl
1658 dnl ---------------------------------------------------------------------------
1659 dnl CF_FUNC_DLSYM version: 3 updated: 2012/10/06 11:17:15
1660 dnl -------------
1661 dnl Test for dlsym() and related functions, as well as libdl.
1662 dnl
1663 dnl Sets
1664 dnl     $cf_have_dlsym
1665 dnl     $cf_have_libdl
1666 AC_DEFUN([CF_FUNC_DLSYM],[
1667 cf_have_dlsym=no
1668 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1669
1670 cf_have_libdl=no
1671 AC_CHECK_LIB(dl,dlsym,[
1672         cf_have_dlsym=yes
1673         cf_have_libdl=yes])])
1674
1675 if test "$cf_have_dlsym" = yes ; then
1676         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1677
1678         AC_MSG_CHECKING(whether able to link to dl*() functions)
1679         AC_TRY_LINK([#include <dlfcn.h>],[
1680                 void *obj;
1681                 if ((obj = dlopen("filename", 0)) != 0) {
1682                         if (dlsym(obj, "symbolname") == 0) {
1683                         dlclose(obj);
1684                         }
1685                 }],[
1686                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1687                 AC_MSG_ERROR(Cannot link test program for libdl)])
1688         AC_MSG_RESULT(ok)
1689 else
1690         AC_MSG_ERROR(Cannot find dlsym function)
1691 fi
1692 ])
1693 dnl ---------------------------------------------------------------------------
1694 dnl CF_FUNC_MEMMOVE version: 8 updated: 2012/10/04 20:12:20
1695 dnl ---------------
1696 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1697 dnl is found, add our own version of memmove to the list of objects.
1698 AC_DEFUN([CF_FUNC_MEMMOVE],
1699 [
1700 AC_CHECK_FUNC(memmove,,[
1701 AC_CHECK_FUNC(bcopy,[
1702         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1703                 AC_TRY_RUN([
1704 int main() {
1705         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1706         char temp[40];
1707         bcopy(data, temp, sizeof(data));
1708         bcopy(temp+10, temp, 15);
1709         bcopy(temp+5, temp+15, 10);
1710         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1711 }
1712                 ],
1713                 [cf_cv_good_bcopy=yes],
1714                 [cf_cv_good_bcopy=no],
1715                 [cf_cv_good_bcopy=unknown])
1716                 ])
1717         ],[cf_cv_good_bcopy=no])
1718         if test "$cf_cv_good_bcopy" = yes ; then
1719                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1720         else
1721                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1722         fi
1723 ])])dnl
1724 dnl ---------------------------------------------------------------------------
1725 dnl CF_FUNC_NANOSLEEP version: 4 updated: 2012/10/06 17:56:13
1726 dnl -----------------
1727 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1728 dnl AIX 4.x, provide a non-working version.
1729 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1730 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1731 AC_TRY_RUN([
1732 #include <stdio.h>
1733 #include <errno.h>
1734 #include <time.h>
1735
1736 #ifdef HAVE_SYS_TIME_H
1737 #include <sys/time.h>
1738 #endif
1739
1740 int main() {
1741         struct timespec ts1, ts2;
1742         int code;
1743         ts1.tv_sec  = 0;
1744         ts1.tv_nsec = 750000000;
1745         ts2.tv_sec  = 0;
1746         ts2.tv_nsec = 0;
1747         errno = 0;
1748         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1749         ${cf_cv_main_return:-return}(code != 0);
1750 }
1751 ],
1752         [cf_cv_func_nanosleep=yes],
1753         [cf_cv_func_nanosleep=no],
1754         [cf_cv_func_nanosleep=unknown])])
1755
1756 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1757 ])
1758 dnl ---------------------------------------------------------------------------
1759 dnl CF_FUNC_OPENPTY version: 3 updated: 2010/05/29 16:31:02
1760 dnl ---------------
1761 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1762 dnl "util" library as well.
1763 AC_DEFUN([CF_FUNC_OPENPTY],
1764 [
1765 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1766 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1767     cf_save_LIBS="$LIBS"
1768     test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1769     for cf_header in pty.h libutil.h util.h
1770     do
1771     AC_TRY_LINK([
1772 #include <$cf_header>
1773 ],[
1774     int x = openpty((int *)0, (int *)0, (char *)0,
1775                    (struct termios *)0, (struct winsize *)0);
1776 ],[
1777         cf_cv_func_openpty=$cf_header
1778         break
1779 ],[
1780         cf_cv_func_openpty=no
1781 ])
1782     done
1783     LIBS="$cf_save_LIBS"
1784 ])
1785 ])dnl
1786 dnl ---------------------------------------------------------------------------
1787 dnl CF_FUNC_POLL version: 8 updated: 2012/10/04 05:24:07
1788 dnl ------------
1789 dnl See if the poll function really works.  Some platforms have poll(), but
1790 dnl it does not work for terminals or files.
1791 AC_DEFUN([CF_FUNC_POLL],[
1792 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1793 AC_TRY_RUN([
1794 #include <stdlib.h>
1795 #include <stdio.h>
1796 #include <unistd.h>
1797 #include <fcntl.h>
1798 #ifdef HAVE_POLL_H
1799 #include <poll.h>
1800 #else
1801 #include <sys/poll.h>
1802 #endif
1803 int main() {
1804         struct pollfd myfds;
1805         int ret;
1806
1807         /* check for Darwin bug with respect to "devices" */
1808         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
1809         if (myfds.fd < 0)
1810                 myfds.fd = 0;
1811         myfds.events = POLLIN;
1812         myfds.revents = 0;
1813
1814         ret = poll(&myfds, 1, 100);
1815
1816         if (ret < 0 || (myfds.revents & POLLNVAL)) {
1817                 ret = -1;
1818         } else {
1819                 int fd = 0;
1820                 if (!isatty(fd)) {
1821                         fd = open("/dev/tty", 2);       /* O_RDWR */
1822                 }
1823
1824                 if (fd >= 0) {
1825                         /* also check with standard input */
1826                         myfds.fd = fd;
1827                         myfds.events = POLLIN;
1828                         myfds.revents = 0;
1829                         ret = poll(&myfds, 1, 100);
1830                 } else {
1831                         ret = -1;
1832                 }
1833         }
1834         ${cf_cv_main_return:-return}(ret < 0);
1835 }],
1836         [cf_cv_working_poll=yes],
1837         [cf_cv_working_poll=no],
1838         [cf_cv_working_poll=unknown])])
1839 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
1840 ])dnl
1841 dnl ---------------------------------------------------------------------------
1842 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
1843 dnl ---------------
1844 dnl Some old/broken variations define tcgetattr() only as a macro in
1845 dnl termio(s).h
1846 AC_DEFUN([CF_FUNC_TERMIOS],[
1847 AC_REQUIRE([CF_STRUCT_TERMIOS])
1848 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1849 AC_TRY_LINK([
1850 #include <sys/types.h>
1851 #ifdef HAVE_UNISTD_H
1852 #include <unistd.h>
1853 #endif
1854 #ifdef HAVE_TERMIOS_H
1855 #include <termios.h>
1856 #define TTY struct termios
1857 #else
1858 #ifdef HAVE_TERMIO_H
1859 #include <termio.h>
1860 #define TTY struct termio
1861 #endif
1862 #endif
1863 ],[
1864 TTY foo;
1865 tcgetattr(1, &foo);],
1866 [cf_cv_have_tcgetattr=yes],
1867 [cf_cv_have_tcgetattr=no])])
1868 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
1869 ])dnl
1870 dnl ---------------------------------------------------------------------------
1871 dnl CF_FUNC_VSSCANF version: 4 updated: 2012/10/06 17:56:13
1872 dnl ---------------
1873 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1874 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1875 dnl other functions.
1876 AC_DEFUN([CF_FUNC_VSSCANF],
1877 [
1878 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1879 AC_TRY_LINK([
1880 #include <stdarg.h>
1881 #include <stdio.h>],[
1882         va_list ap;
1883         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1884 AC_TRY_LINK([
1885 #include <stdarg.h>
1886 #include <stdio.h>],[
1887     FILE strbuf;
1888     char *str = "from";
1889
1890     strbuf._flag = _IOREAD;
1891     strbuf._ptr = strbuf._base = (unsigned char *) str;
1892     strbuf._cnt = strlen(str);
1893     strbuf._file = _NFILE;
1894     return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1895 AC_TRY_LINK([
1896 #include <stdarg.h>
1897 #include <stdio.h>],[
1898     FILE strbuf;
1899     char *str = "from";
1900
1901     strbuf._flag = _IOREAD;
1902     strbuf._ptr = strbuf._base = (unsigned char *) str;
1903     strbuf._cnt = strlen(str);
1904     strbuf._file = _NFILE;
1905     return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1906 cf_cv_func_vsscanf=no])])])])
1907
1908 case $cf_cv_func_vsscanf in #(vi
1909 vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);; #(vi
1910 vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);; #(vi
1911 _doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
1912 esac
1913
1914 ])dnl
1915 dnl ---------------------------------------------------------------------------
1916 dnl CF_GCC_ATTRIBUTES version: 16 updated: 2012/10/02 20:55:03
1917 dnl -----------------
1918 dnl Test for availability of useful gcc __attribute__ directives to quiet
1919 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1920 dnl to documentation, unrecognized directives cause older compilers to barf.
1921 AC_DEFUN([CF_GCC_ATTRIBUTES],
1922 [
1923 if test "$GCC" = yes
1924 then
1925 cat > conftest.i <<EOF
1926 #ifndef GCC_PRINTF
1927 #define GCC_PRINTF 0
1928 #endif
1929 #ifndef GCC_SCANF
1930 #define GCC_SCANF 0
1931 #endif
1932 #ifndef GCC_NORETURN
1933 #define GCC_NORETURN /* nothing */
1934 #endif
1935 #ifndef GCC_UNUSED
1936 #define GCC_UNUSED /* nothing */
1937 #endif
1938 EOF
1939 if test "$GCC" = yes
1940 then
1941         AC_CHECKING([for $CC __attribute__ directives])
1942 cat > conftest.$ac_ext <<EOF
1943 #line __oline__ "${as_me:-configure}"
1944 #include "confdefs.h"
1945 #include "conftest.h"
1946 #include "conftest.i"
1947 #if     GCC_PRINTF
1948 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1949 #else
1950 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1951 #endif
1952 #if     GCC_SCANF
1953 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1954 #else
1955 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1956 #endif
1957 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1958 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1959 extern void foo(void) GCC_NORETURN;
1960 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1961 EOF
1962         cf_printf_attribute=no
1963         cf_scanf_attribute=no
1964         for cf_attribute in scanf printf unused noreturn
1965         do
1966                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1967                 cf_directive="__attribute__(($cf_attribute))"
1968                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1969
1970                 case $cf_attribute in #(vi
1971                 printf) #(vi
1972                         cf_printf_attribute=yes
1973                         cat >conftest.h <<EOF
1974 #define GCC_$cf_ATTRIBUTE 1
1975 EOF
1976                         ;;
1977                 scanf) #(vi
1978                         cf_scanf_attribute=yes
1979                         cat >conftest.h <<EOF
1980 #define GCC_$cf_ATTRIBUTE 1
1981 EOF
1982                         ;;
1983                 *) #(vi
1984                         cat >conftest.h <<EOF
1985 #define GCC_$cf_ATTRIBUTE $cf_directive
1986 EOF
1987                         ;;
1988                 esac
1989
1990                 if AC_TRY_EVAL(ac_compile); then
1991                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1992                         cat conftest.h >>confdefs.h
1993                         case $cf_attribute in #(vi
1994                         noreturn) #(vi
1995                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1996                                 ;;
1997                         printf) #(vi
1998                                 cf_value='/* nothing */'
1999                                 if test "$cf_printf_attribute" != no ; then
2000                                         cf_value='__attribute__((format(printf,fmt,var)))'
2001                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2002                                 fi
2003                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2004                                 ;;
2005                         scanf) #(vi
2006                                 cf_value='/* nothing */'
2007                                 if test "$cf_scanf_attribute" != no ; then
2008                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2009                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2010                                 fi
2011                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2012                                 ;;
2013                         unused) #(vi
2014                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2015                                 ;;
2016                         esac
2017                 fi
2018         done
2019 else
2020         fgrep define conftest.i >>confdefs.h
2021 fi
2022 rm -rf conftest*
2023 fi
2024 ])dnl
2025 dnl ---------------------------------------------------------------------------
2026 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
2027 dnl --------------
2028 dnl Find version of gcc
2029 AC_DEFUN([CF_GCC_VERSION],[
2030 AC_REQUIRE([AC_PROG_CC])
2031 GCC_VERSION=none
2032 if test "$GCC" = yes ; then
2033         AC_MSG_CHECKING(version of $CC)
2034         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2035         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2036         AC_MSG_RESULT($GCC_VERSION)
2037 fi
2038 ])dnl
2039 dnl ---------------------------------------------------------------------------
2040 dnl CF_GCC_WARNINGS version: 31 updated: 2013/11/19 19:23:35
2041 dnl ---------------
2042 dnl Check if the compiler supports useful warning options.  There's a few that
2043 dnl we don't use, simply because they're too noisy:
2044 dnl
2045 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2046 dnl     -Wredundant-decls (system headers make this too noisy)
2047 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2048 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2049 dnl             is enabled for ncurses using "--enable-const".
2050 dnl     -pedantic
2051 dnl
2052 dnl Parameter:
2053 dnl     $1 is an optional list of gcc warning flags that a particular
2054 dnl             application might want to use, e.g., "no-unused" for
2055 dnl             -Wno-unused
2056 dnl Special:
2057 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2058 dnl
2059 AC_DEFUN([CF_GCC_WARNINGS],
2060 [
2061 AC_REQUIRE([CF_GCC_VERSION])
2062 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2063 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2064
2065 cat > conftest.$ac_ext <<EOF
2066 #line __oline__ "${as_me:-configure}"
2067 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2068 EOF
2069
2070 if test "$INTEL_COMPILER" = yes
2071 then
2072 # The "-wdXXX" options suppress warnings:
2073 # remark #1419: external declaration in primary source file
2074 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2075 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2076 # remark #193: zero used for undefined preprocessing identifier
2077 # remark #593: variable "curs_sb_left_arrow" was set but never used
2078 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2079 # remark #869: parameter "tw" was never referenced
2080 # remark #981: operands are evaluated in unspecified order
2081 # warning #279: controlling expression is constant
2082
2083         AC_CHECKING([for $CC warning options])
2084         cf_save_CFLAGS="$CFLAGS"
2085         EXTRA_CFLAGS="-Wall"
2086         for cf_opt in \
2087                 wd1419 \
2088                 wd1683 \
2089                 wd1684 \
2090                 wd193 \
2091                 wd593 \
2092                 wd279 \
2093                 wd810 \
2094                 wd869 \
2095                 wd981
2096         do
2097                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2098                 if AC_TRY_EVAL(ac_compile); then
2099                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2100                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2101                 fi
2102         done
2103         CFLAGS="$cf_save_CFLAGS"
2104
2105 elif test "$GCC" = yes
2106 then
2107         AC_CHECKING([for $CC warning options])
2108         cf_save_CFLAGS="$CFLAGS"
2109         EXTRA_CFLAGS=
2110         cf_warn_CONST=""
2111         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2112         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2113         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2114         for cf_opt in W Wall \
2115                 Wbad-function-cast \
2116                 Wcast-align \
2117                 Wcast-qual \
2118                 Wdeclaration-after-statement \
2119                 Wextra \
2120                 Winline \
2121                 Wmissing-declarations \
2122                 Wmissing-prototypes \
2123                 Wnested-externs \
2124                 Wpointer-arith \
2125                 Wshadow \
2126                 Wstrict-prototypes \
2127                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2128         do
2129                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2130                 if AC_TRY_EVAL(ac_compile); then
2131                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2132                         case $cf_opt in #(vi
2133                         Wcast-qual) #(vi
2134                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2135                                 ;;
2136                         Winline) #(vi
2137                                 case $GCC_VERSION in
2138                                 [[34]].*)
2139                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2140                                         continue;;
2141                                 esac
2142                                 ;;
2143                         Wpointer-arith) #(vi
2144                                 case $GCC_VERSION in
2145                                 [[12]].*)
2146                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2147                                         continue;;
2148                                 esac
2149                                 ;;
2150                         esac
2151                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2152                 fi
2153         done
2154         CFLAGS="$cf_save_CFLAGS"
2155 fi
2156 rm -rf conftest*
2157
2158 AC_SUBST(EXTRA_CFLAGS)
2159 ])dnl
2160 dnl ---------------------------------------------------------------------------
2161 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2162 dnl ----------------
2163 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2164 dnl unistd.h or (nonstandard) in getopt.h
2165 AC_DEFUN([CF_GETOPT_HEADER],
2166 [
2167 AC_HAVE_HEADERS(unistd.h getopt.h)
2168 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2169 cf_cv_getopt_header=none
2170 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2171 do
2172 AC_TRY_COMPILE([
2173 #include <$cf_header>],
2174 [int x = optind; char *y = optarg],
2175 [cf_cv_getopt_header=$cf_header
2176  break])
2177 done
2178 ])
2179 if test $cf_cv_getopt_header != none ; then
2180         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2181 fi
2182 if test $cf_cv_getopt_header = getopt.h ; then
2183         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2184 fi
2185 ])dnl
2186 dnl ---------------------------------------------------------------------------
2187 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2188 dnl -----------------
2189 AC_DEFUN([CF_GNATPREP_OPT_T],[
2190 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2191 cf_cv_gnatprep_opt_t=no
2192 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2193 ])
2194 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2195 AC_SUBST(GNATPREP_OPTS)
2196 ])dnl
2197 dnl ---------------------------------------------------------------------------
2198 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
2199 dnl ----------------
2200 AC_DEFUN([CF_GNAT_GENERICS],
2201 [
2202 AC_REQUIRE([CF_GNAT_VERSION])
2203
2204 AC_MSG_CHECKING(if GNAT supports generics)
2205 case $cf_gnat_version in #(vi
2206 3.[[1-9]]*|[[4-9]].*) #(vi
2207         cf_gnat_generics=yes
2208         ;;
2209 *)
2210         cf_gnat_generics=no
2211         ;;
2212 esac
2213 AC_MSG_RESULT($cf_gnat_generics)
2214
2215 if test "$cf_gnat_generics" = yes
2216 then
2217         cf_compile_generics=generics
2218         cf_generic_objects="\${GENOBJS}"
2219 else
2220         cf_compile_generics=
2221         cf_generic_objects=
2222 fi
2223
2224 AC_SUBST(cf_compile_generics)
2225 AC_SUBST(cf_generic_objects)
2226 ])dnl
2227 dnl ---------------------------------------------------------------------------
2228 dnl CF_GNAT_PROJECTS version: 7 updated: 2014/06/01 10:46:34
2229 dnl ----------------
2230 dnl GNAT projects are configured with ".gpr" project files.
2231 dnl GNAT libraries are a further development, using the project feature.
2232 AC_DEFUN([CF_GNAT_PROJECTS],
2233 [
2234 AC_REQUIRE([CF_GNAT_VERSION])
2235 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2236
2237 cf_gnat_libraries=no
2238 cf_gnat_projects=no
2239
2240 if test "$enable_gnat_projects" != no ; then
2241 AC_MSG_CHECKING(if GNAT supports project files)
2242 case $cf_gnat_version in #(vi
2243 3.[[0-9]]*) #(vi
2244         ;;
2245 *)
2246         case $cf_cv_system_name in #(vi
2247         cygwin*|msys*) #(vi
2248                 ;;
2249         *)
2250                 mkdir conftest.src conftest.bin conftest.lib
2251                 cd conftest.src
2252                 rm -rf conftest* *~conftest*
2253                 cat >>library.gpr <<CF_EOF
2254 project Library is
2255   Kind := External ("LIB_KIND");
2256   for Library_Name use "ConfTest";
2257   for Object_Dir use ".";
2258   for Library_ALI_Dir use External("LIBRARY_DIR");
2259   for Library_Version use External ("SONAME");
2260   for Library_Kind use Kind;
2261   for Library_Dir use External("BUILD_DIR");
2262   Source_Dir := External ("SOURCE_DIR");
2263   for Source_Dirs use (Source_Dir);
2264 end Library;
2265 CF_EOF
2266                 cat >>confpackage.ads <<CF_EOF
2267 package ConfPackage is
2268    procedure conftest;
2269 end ConfPackage;
2270 CF_EOF
2271                 cat >>confpackage.adb <<CF_EOF
2272 with Text_IO;
2273 package body ConfPackage is
2274    procedure conftest is
2275    begin
2276       Text_IO.Put ("Hello World");
2277       Text_IO.New_Line;
2278    end conftest;
2279 end ConfPackage;
2280 CF_EOF
2281                 if ( $cf_ada_make $ADAFLAGS \
2282                                 -Plibrary.gpr \
2283                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2284                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2285                                 -XSOURCE_DIR=`pwd` \
2286                                 -XSONAME=libConfTest.so.1 \
2287                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2288                         cf_gnat_projects=yes
2289                 fi
2290                 cd ..
2291                 if test -f conftest.lib/confpackage.ali
2292                 then
2293                         cf_gnat_libraries=yes
2294                 fi
2295                 rm -rf conftest* *~conftest*
2296                 ;;
2297         esac
2298         ;;
2299 esac
2300 AC_MSG_RESULT($cf_gnat_projects)
2301 fi # enable_gnat_projects
2302
2303 if test $cf_gnat_projects = yes
2304 then
2305         AC_MSG_CHECKING(if GNAT supports libraries)
2306         AC_MSG_RESULT($cf_gnat_libraries)
2307 fi
2308
2309 if test "$cf_gnat_projects" = yes
2310 then
2311         USE_OLD_MAKERULES="#"
2312         USE_GNAT_PROJECTS=""
2313 else
2314         USE_OLD_MAKERULES=""
2315         USE_GNAT_PROJECTS="#"
2316 fi
2317
2318 if test "$cf_gnat_libraries" = yes
2319 then
2320         USE_GNAT_LIBRARIES=""
2321 else
2322         USE_GNAT_LIBRARIES="#"
2323 fi
2324
2325 AC_SUBST(USE_OLD_MAKERULES)
2326 AC_SUBST(USE_GNAT_PROJECTS)
2327 AC_SUBST(USE_GNAT_LIBRARIES)
2328 ])dnl
2329 dnl ---------------------------------------------------------------------------
2330 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2331 dnl --------------
2332 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2333 dnl is noted that gnat may compile a tasking unit even for configurations which
2334 dnl fail at runtime.
2335 AC_DEFUN([CF_GNAT_SIGINT],[
2336 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2337 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2338
2339 package ConfTest is
2340
2341    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2342    pragma Unreserve_All_Interrupts;
2343    pragma Warnings (On);
2344
2345    protected Process is
2346       procedure Stop;
2347       function Continue return Boolean;
2348       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2349    private
2350       Done : Boolean := False;
2351    end Process;
2352
2353 end ConfTest;],
2354 [package body ConfTest is
2355    protected body Process is
2356       procedure Stop is
2357       begin
2358          Done := True;
2359       end Stop;
2360       function Continue return Boolean is
2361       begin
2362          return not Done;
2363       end Continue;
2364    end Process;
2365 end ConfTest;],
2366         [cf_cv_gnat_sigint=yes],
2367         [cf_cv_gnat_sigint=no])])
2368
2369 if test $cf_cv_gnat_sigint = yes ; then
2370         USE_GNAT_SIGINT=""
2371 else
2372         USE_GNAT_SIGINT="#"
2373 fi
2374 AC_SUBST(USE_GNAT_SIGINT)
2375 ])dnl
2376 dnl ---------------------------------------------------------------------------
2377 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2378 dnl ----------------
2379 dnl Verify that a test program compiles/links with GNAT.
2380 dnl $cf_ada_make is set to the program that compiles/links
2381 dnl $ADAFLAGS may be set to the GNAT flags.
2382 dnl
2383 dnl $1 is the text of the spec
2384 dnl $2 is the text of the body
2385 dnl $3 is the shell command to execute if successful
2386 dnl $4 is the shell command to execute if not successful
2387 AC_DEFUN([CF_GNAT_TRY_LINK],
2388 [
2389 rm -rf conftest* *~conftest*
2390 cat >>conftest.ads <<CF_EOF
2391 $1
2392 CF_EOF
2393 cat >>conftest.adb <<CF_EOF
2394 $2
2395 CF_EOF
2396 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2397 ifelse($3,,      :,[      $3])
2398 ifelse($4,,,[else
2399    $4])
2400 fi
2401 rm -rf conftest* *~conftest*
2402 ])dnl
2403 dnl ---------------------------------------------------------------------------
2404 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2405 dnl ---------------
2406 dnl Verify that a test program compiles and runs with GNAT
2407 dnl $cf_ada_make is set to the program that compiles/links
2408 dnl $ADAFLAGS may be set to the GNAT flags.
2409 dnl
2410 dnl $1 is the text of the spec
2411 dnl $2 is the text of the body
2412 dnl $3 is the shell command to execute if successful
2413 dnl $4 is the shell command to execute if not successful
2414 AC_DEFUN([CF_GNAT_TRY_RUN],
2415 [
2416 rm -rf conftest* *~conftest*
2417 cat >>conftest.ads <<CF_EOF
2418 $1
2419 CF_EOF
2420 cat >>conftest.adb <<CF_EOF
2421 $2
2422 CF_EOF
2423 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2424    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2425 ifelse($3,,      :,[      $3])
2426 ifelse($4,,,[   else
2427       $4])
2428    fi
2429 ifelse($4,,,[else
2430    $4])
2431 fi
2432 rm -rf conftest* *~conftest*
2433 ])dnl
2434 dnl ---------------------------------------------------------------------------
2435 dnl CF_GNAT_VERSION version: 18 updated: 2012/01/21 19:28:10
2436 dnl ---------------
2437 dnl Verify version of GNAT.
2438 AC_DEFUN([CF_GNAT_VERSION],
2439 [
2440 AC_MSG_CHECKING(for gnat version)
2441 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2442         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2443     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2444 AC_MSG_RESULT($cf_gnat_version)
2445
2446 case $cf_gnat_version in #(vi
2447 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]]) #(vi
2448         cf_cv_prog_gnat_correct=yes
2449         ;;
2450 *)
2451         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2452         cf_cv_prog_gnat_correct=no
2453         ;;
2454 esac
2455 ])
2456 dnl ---------------------------------------------------------------------------
2457 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2458 dnl -------------
2459 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2460 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2461 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2462 dnl since it is interwoven with GNU extensions.
2463 dnl
2464 dnl Well, yes we could work around it...
2465 AC_DEFUN([CF_GNU_SOURCE],
2466 [
2467 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2468 AC_TRY_COMPILE([#include <sys/types.h>],[
2469 #ifndef _XOPEN_SOURCE
2470 make an error
2471 #endif],
2472         [cf_cv_gnu_source=no],
2473         [cf_save="$CPPFLAGS"
2474          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2475          AC_TRY_COMPILE([#include <sys/types.h>],[
2476 #ifdef _XOPEN_SOURCE
2477 make an error
2478 #endif],
2479         [cf_cv_gnu_source=no],
2480         [cf_cv_gnu_source=yes])
2481         CPPFLAGS="$cf_save"
2482         ])
2483 ])
2484 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2485 ])dnl
2486 dnl ---------------------------------------------------------------------------
2487 dnl CF_GPP_LIBRARY version: 11 updated: 2012/10/06 17:56:13
2488 dnl --------------
2489 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2490 dnl problem :-).  If we have the compiler but no library, we'll be able to
2491 dnl configure, but won't be able to build the c++ demo program.
2492 AC_DEFUN([CF_GPP_LIBRARY],
2493 [
2494 cf_cxx_library=unknown
2495 case $cf_cv_system_name in #(vi
2496 os2*) #(vi
2497         cf_gpp_libname=gpp
2498         ;;
2499 *)
2500         cf_gpp_libname=g++
2501         ;;
2502 esac
2503 if test "$GXX" = yes; then
2504         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2505         cf_save="$LIBS"
2506         CF_ADD_LIB($cf_gpp_libname)
2507         AC_TRY_LINK([
2508 #include <$cf_gpp_libname/builtin.h>
2509         ],
2510         [two_arg_error_handler_t foo2 = lib_error_handler],
2511         [cf_cxx_library=yes
2512          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2513          if test "$cf_gpp_libname" = cpp ; then
2514             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2515          else
2516             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2517          fi],
2518         [AC_TRY_LINK([
2519 #include <builtin.h>
2520         ],
2521         [two_arg_error_handler_t foo2 = lib_error_handler],
2522         [cf_cxx_library=yes
2523          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2524          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2525         [cf_cxx_library=no])])
2526         LIBS="$cf_save"
2527         AC_MSG_RESULT($cf_cxx_library)
2528 fi
2529 ])dnl
2530 dnl ---------------------------------------------------------------------------
2531 dnl CF_GXX_VERSION version: 7 updated: 2012/06/16 14:55:39
2532 dnl --------------
2533 dnl Check for version of g++
2534 AC_DEFUN([CF_GXX_VERSION],[
2535 AC_REQUIRE([AC_PROG_CPP])
2536 GXX_VERSION=none
2537 if test "$GXX" = yes; then
2538         AC_MSG_CHECKING(version of ${CXX:-g++})
2539         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2540         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2541         AC_MSG_RESULT($GXX_VERSION)
2542 fi
2543 ])dnl
2544 dnl ---------------------------------------------------------------------------
2545 dnl CF_GXX_WARNINGS version: 8 updated: 2013/11/16 14:27:53
2546 dnl ---------------
2547 dnl Check if the compiler supports useful warning options.
2548 dnl
2549 dnl Most of gcc's options apply to g++, except:
2550 dnl     -Wbad-function-cast
2551 dnl     -Wmissing-declarations
2552 dnl     -Wnested-externs
2553 dnl
2554 dnl Omit a few (for now):
2555 dnl     -Winline
2556 dnl
2557 dnl Parameter:
2558 dnl     $1 is an optional list of g++ warning flags that a particular
2559 dnl             application might want to use, e.g., "no-unused" for
2560 dnl             -Wno-unused
2561 dnl Special:
2562 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2563 dnl
2564 AC_DEFUN([CF_GXX_WARNINGS],
2565 [
2566
2567 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2568 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2569
2570 AC_REQUIRE([CF_GXX_VERSION])
2571
2572 AC_LANG_SAVE
2573 AC_LANG_CPLUSPLUS
2574
2575 cat > conftest.$ac_ext <<EOF
2576 #line __oline__ "configure"
2577 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2578 EOF
2579
2580 if test "$INTEL_CPLUSPLUS" = yes
2581 then
2582 # The "-wdXXX" options suppress warnings:
2583 # remark #1419: external declaration in primary source file
2584 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2585 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2586 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2587 # remark #193: zero used for undefined preprocessing identifier
2588 # remark #593: variable "curs_sb_left_arrow" was set but never used
2589 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2590 # remark #869: parameter "tw" was never referenced
2591 # remark #981: operands are evaluated in unspecified order
2592 # warning #269: invalid format string conversion
2593
2594         AC_CHECKING([for $CC warning options])
2595         cf_save_CXXFLAGS="$CXXFLAGS"
2596         EXTRA_CXXFLAGS="-Wall"
2597         for cf_opt in \
2598                 wd1419 \
2599                 wd1682 \
2600                 wd1683 \
2601                 wd1684 \
2602                 wd193 \
2603                 wd279 \
2604                 wd593 \
2605                 wd810 \
2606                 wd869 \
2607                 wd981
2608         do
2609                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2610                 if AC_TRY_EVAL(ac_compile); then
2611                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2612                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2613                 fi
2614         done
2615         CXXFLAGS="$cf_save_CXXFLAGS"
2616
2617 elif test "$GXX" = yes
2618 then
2619         AC_CHECKING([for $CXX warning options])
2620         cf_save_CXXFLAGS="$CXXFLAGS"
2621         EXTRA_CXXFLAGS="-W -Wall"
2622         cf_gxx_extra_warnings=""
2623         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2624         case "$GCC_VERSION" in
2625         [[1-2]].*)
2626                 ;;
2627         *)
2628                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2629                 ;;
2630         esac
2631         for cf_opt in \
2632                 Wabi \
2633                 fabi-version=0 \
2634                 Wextra \
2635                 Wignored-qualifiers \
2636                 Wlogical-op \
2637                 Woverloaded-virtual \
2638                 Wsign-promo \
2639                 Wsynth \
2640                 Wold-style-cast \
2641                 Wcast-align \
2642                 Wcast-qual \
2643                 Wpointer-arith \
2644                 Wshadow \
2645                 Wundef $cf_gxx_extra_warnings $1
2646         do
2647                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2648                 if AC_TRY_EVAL(ac_compile); then
2649                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2650                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2651                 else
2652                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2653                 fi
2654         done
2655         CXXFLAGS="$cf_save_CXXFLAGS"
2656 fi
2657
2658 rm -rf conftest*
2659 AC_LANG_RESTORE
2660 AC_SUBST(EXTRA_CXXFLAGS)
2661 ])dnl
2662 dnl ---------------------------------------------------------------------------
2663 dnl CF_HASHED_DB version: 5 updated: 2014/04/12 16:47:01
2664 dnl ------------
2665 dnl Look for an instance of the Berkeley hashed database.
2666 dnl
2667 dnl $1 = optional parameter, to specify install-prefix for the database.
2668 AC_DEFUN([CF_HASHED_DB],
2669 [
2670 ifelse([$1],,,[
2671 case $1 in #(vi
2672 yes|*able*) #(vi
2673     ;;
2674 *)
2675     if test -d "$1" ; then
2676         CF_ADD_INCDIR($1/include)
2677         CF_ADD_LIBDIR($1/lib)
2678         else
2679                 case "$1" in #(vi
2680                 ./*|../*|/*)
2681                         AC_MSG_WARN(no such directory $1)
2682                         ;; #(vi
2683                 *)
2684                         CF_FIND_SUB_INCDIR($1)
2685                         CF_FIND_SUB_LIBDIR($1)
2686                         ;;
2687                 esac
2688     fi
2689 esac
2690 ])
2691 AC_CHECK_HEADER(db.h,[
2692 CF_HASHED_DB_VERSION
2693 if test "$cf_cv_hashed_db_version" = unknown ; then
2694         AC_MSG_ERROR(Cannot determine version of db)
2695 else
2696         CF_HASHED_DB_LIBS
2697         if test "$cf_cv_hashed_db_libs" = unknown ; then
2698                 AC_MSG_ERROR(Cannot determine library for db)
2699         elif test "$cf_cv_hashed_db_libs" != default ; then
2700                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2701         fi
2702 fi
2703 ],[
2704         AC_MSG_ERROR(Cannot find db.h)
2705 ])
2706 ])dnl
2707 dnl ---------------------------------------------------------------------------
2708 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2709 dnl -----------------
2710 dnl Given that we have the header and version for hashed database, find the
2711 dnl library information.
2712 AC_DEFUN([CF_HASHED_DB_LIBS],
2713 [
2714 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2715 cf_cv_hashed_db_libs=unknown
2716 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2717 do
2718         cf_save_libs="$LIBS"
2719         if test -n "$cf_db_libs"; then
2720                 CF_ADD_LIB($cf_db_libs)
2721         fi
2722         CF_MSG_LOG(checking for library "$cf_db_libs")
2723         AC_TRY_LINK([
2724 $ac_includes_default
2725 #include <db.h>
2726 ],[
2727         char *path = "/tmp/foo";
2728 #ifdef DB_VERSION_MAJOR
2729 #if DB_VERSION_MAJOR >= 4
2730         DB *result = 0;
2731         db_create(&result, NULL, 0);
2732         result->open(result,
2733                 NULL,
2734                 path,
2735                 path,
2736                 DB_HASH,
2737                 DB_CREATE,
2738                 0644);
2739 #elif DB_VERSION_MAJOR >= 3
2740         DB *result = 0;
2741         db_create(&result, NULL, 0);
2742         result->open(result,
2743                 path,
2744                 path,
2745                 DB_HASH,
2746                 DB_CREATE,
2747                 0644);
2748 #elif DB_VERSION_MAJOR >= 2
2749         DB *result = 0;
2750         db_open(path,
2751                 DB_HASH,
2752                 DB_CREATE,
2753                 0644,
2754                 (DB_ENV *) 0,
2755                 (DB_INFO *) 0,
2756                 &result);
2757 #endif /* DB_VERSION_MAJOR */
2758 #else
2759         DB *result = dbopen(path,
2760                      2,
2761                      0644,
2762                      DB_HASH,
2763                      0);
2764 #endif
2765         ${cf_cv_main_return:-return}(result != 0)
2766 ],[
2767         if test -n "$cf_db_libs" ; then
2768                 cf_cv_hashed_db_libs=$cf_db_libs
2769         else
2770                 cf_cv_hashed_db_libs=default
2771         fi
2772         LIBS="$cf_save_libs"
2773         break
2774 ])
2775         LIBS="$cf_save_libs"
2776 done
2777 ])
2778 ])dnl
2779 dnl ---------------------------------------------------------------------------
2780 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
2781 dnl --------------------
2782 dnl Given that we have the header file for hashed database, find the version
2783 dnl information.
2784 AC_DEFUN([CF_HASHED_DB_VERSION],
2785 [
2786 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2787 cf_cv_hashed_db_version=unknown
2788
2789 for cf_db_version in 1 2 3 4 5 6
2790 do
2791         CF_MSG_LOG(checking for db version $cf_db_version)
2792         AC_TRY_COMPILE([
2793 $ac_includes_default
2794 #include <db.h>
2795
2796 #ifdef DB_VERSION_MAJOR
2797         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2798 #if $cf_db_version == DB_VERSION_MAJOR
2799         /* ok */
2800 #else
2801         make an error
2802 #endif
2803 #else
2804 #if $cf_db_version == 1
2805         /* ok: assuming this is DB 1.8.5 */
2806 #else
2807         make an error
2808 #endif
2809 #endif
2810 ],[DBT *foo = 0],[
2811         cf_cv_hashed_db_version=$cf_db_version
2812         break
2813         ])
2814 done
2815 ])
2816 ])dnl
2817 dnl ---------------------------------------------------------------------------
2818 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
2819 dnl --------------
2820 dnl Construct a search-list of directories for a nonstandard header-file
2821 dnl
2822 dnl Parameters
2823 dnl     $1 = the variable to return as result
2824 dnl     $2 = the package name
2825 AC_DEFUN([CF_HEADER_PATH],
2826 [
2827 $1=
2828
2829 # collect the current set of include-directories from compiler flags
2830 cf_header_path_list=""
2831 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2832         for cf_header_path in $CPPFLAGS $CFLAGS
2833         do
2834                 case $cf_header_path in #(vi
2835                 -I*)
2836                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2837                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2838                         cf_header_path_list="$cf_header_path_list [$]$1"
2839                         ;;
2840                 esac
2841         done
2842 fi
2843
2844 # add the variations for the package we are looking for
2845 CF_SUBDIR_PATH($1,$2,include)
2846
2847 test "$includedir" != NONE && \
2848 test "$includedir" != "/usr/include" && \
2849 test -d "$includedir" && {
2850         test -d $includedir &&    $1="[$]$1 $includedir"
2851         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2852 }
2853
2854 test "$oldincludedir" != NONE && \
2855 test "$oldincludedir" != "/usr/include" && \
2856 test -d "$oldincludedir" && {
2857         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2858         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2859 }
2860
2861 $1="[$]$1 $cf_header_path_list"
2862 ])dnl
2863 dnl ---------------------------------------------------------------------------
2864 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2865 dnl ---------------
2866 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2867 AC_DEFUN([CF_HELP_MESSAGE],
2868 [AC_DIVERT_HELP([$1])dnl
2869 ])dnl
2870 dnl ---------------------------------------------------------------------------
2871 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
2872 dnl ---------------
2873 dnl Construct the list of include-options according to whether we're building
2874 dnl in the source directory or using '--srcdir=DIR' option.
2875 AC_DEFUN([CF_INCLUDE_DIRS],
2876 [
2877 if test "$srcdir" != "."; then
2878         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
2879 fi
2880 CPPFLAGS="-I../include $CPPFLAGS"
2881 if test "$srcdir" != "."; then
2882         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
2883 fi
2884 CPPFLAGS="-I. $CPPFLAGS"
2885 AC_SUBST(CPPFLAGS)
2886 ])dnl
2887 dnl ---------------------------------------------------------------------------
2888 dnl CF_INTEL_COMPILER version: 6 updated: 2014/03/17 13:13:07
2889 dnl -----------------
2890 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2891 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2892 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2893 dnl
2894 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2895 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2896 dnl the wrappers for gcc and g++ warnings.
2897 dnl
2898 dnl $1 = GCC (default) or GXX
2899 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2900 dnl $3 = CFLAGS (default) or CXXFLAGS
2901 AC_DEFUN([CF_INTEL_COMPILER],[
2902 AC_REQUIRE([AC_CANONICAL_HOST])
2903 ifelse([$2],,INTEL_COMPILER,[$2])=no
2904
2905 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2906         case $host_os in
2907         linux*|gnu*)
2908                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2909                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2910                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2911                 AC_TRY_COMPILE([],[
2912 #ifdef __INTEL_COMPILER
2913 #else
2914 make an error
2915 #endif
2916 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2917 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
2918 ],[])
2919                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2920                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2921                 ;;
2922         esac
2923 fi
2924 ])dnl
2925 dnl ---------------------------------------------------------------------------
2926 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
2927 dnl ----------
2928 dnl Check if we have either a function or macro for 'isascii()'.
2929 AC_DEFUN([CF_ISASCII],
2930 [
2931 AC_MSG_CHECKING(for isascii)
2932 AC_CACHE_VAL(cf_cv_have_isascii,[
2933         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2934         [cf_cv_have_isascii=yes],
2935         [cf_cv_have_isascii=no])
2936 ])dnl
2937 AC_MSG_RESULT($cf_cv_have_isascii)
2938 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
2939 ])dnl
2940 dnl ---------------------------------------------------------------------------
2941 dnl CF_LARGEFILE version: 8 updated: 2012/10/06 08:57:51
2942 dnl ------------
2943 dnl Add checks for large file support.
2944 AC_DEFUN([CF_LARGEFILE],[
2945 ifdef([AC_FUNC_FSEEKO],[
2946     AC_SYS_LARGEFILE
2947     if test "$enable_largefile" != no ; then
2948         AC_FUNC_FSEEKO
2949
2950         # Normally we would collect these definitions in the config.h,
2951         # but (like _XOPEN_SOURCE), some environments rely on having these
2952         # defined before any of the system headers are included.  Another
2953         # case comes up with C++, e.g., on AIX the compiler compiles the
2954         # header files by themselves before looking at the body files it is
2955         # told to compile.  For ncurses, those header files do not include
2956         # the config.h
2957         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2958         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2959         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2960
2961         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2962                 AC_TRY_COMPILE([
2963 #include <sys/types.h>
2964 #include <dirent.h>
2965                 ],[
2966                 /* if transitional largefile support is setup, this is true */
2967                 extern struct dirent64 * readdir(DIR *);
2968                 struct dirent64 *x = readdir((DIR *)0);
2969                 struct dirent *y = readdir((DIR *)0);
2970                 int z = x - y;
2971                 ],
2972                 [cf_cv_struct_dirent64=yes],
2973                 [cf_cv_struct_dirent64=no])
2974         ])
2975         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
2976     fi
2977 ])
2978 ])
2979 dnl ---------------------------------------------------------------------------
2980 dnl CF_LDFLAGS_STATIC version: 10 updated: 2011/09/24 12:51:48
2981 dnl -----------------
2982 dnl Check for compiler/linker flags used to temporarily force usage of static
2983 dnl libraries.  This depends on the compiler and platform.  Use this to help
2984 dnl ensure that the linker picks up a given library based on its position in
2985 dnl the list of linker options and libraries.
2986 AC_DEFUN([CF_LDFLAGS_STATIC],[
2987
2988 if test "$GCC" = yes ; then
2989         case $cf_cv_system_name in #(
2990         OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)         #( vi
2991                 LDFLAGS_STATIC=
2992                 LDFLAGS_SHARED=
2993                 ;;
2994     *)  #( normally, except when broken
2995         LDFLAGS_STATIC=-static
2996         LDFLAGS_SHARED=-dynamic
2997         ;;
2998     esac
2999 else
3000         case $cf_cv_system_name in #(
3001         aix[[4-7]]*)    #( from ld manpage
3002                 LDFLAGS_STATIC=-bstatic
3003                 LDFLAGS_SHARED=-bdynamic
3004                 ;;
3005         hpux*)          #( from ld manpage for hpux10.20, hpux11.11
3006                 # We could also use just "archive" and "shared".
3007                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3008                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3009                 ;;
3010         irix*)          #( from ld manpage IRIX64
3011                 LDFLAGS_STATIC=-Bstatic
3012                 LDFLAGS_SHARED=-Bdynamic
3013                 ;;
3014         osf[[45]]*)     #( from ld manpage osf4.0d, osf5.1
3015                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3016                 LDFLAGS_STATIC=-noso
3017                 LDFLAGS_SHARED=-so_archive
3018                 ;;
3019         solaris2*)
3020                 LDFLAGS_STATIC=-Bstatic
3021                 LDFLAGS_SHARED=-Bdynamic
3022                 ;;
3023         esac
3024 fi
3025
3026 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3027 then
3028         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3029
3030         rm -f libconftest.a
3031         cat >conftest.$ac_ext <<EOF
3032 #line __oline__ "configure"
3033 #include <stdio.h>
3034 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3035 EOF
3036         if AC_TRY_EVAL(ac_compile) ; then
3037                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3038                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3039         fi
3040         rm -f conftest.*
3041
3042         cf_save_LIBS="$LIBS"
3043
3044         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3045         AC_TRY_LINK([
3046 #line __oline__ "configure"
3047 #include <stdio.h>
3048 int cf_ldflags_static(FILE *fp);
3049 ],[
3050         return cf_ldflags_static(stdin);
3051 ],[
3052         # some linkers simply ignore the -dynamic
3053         case x`file conftest$ac_exeext 2>/dev/null` in #(vi
3054         *static*) # (vi
3055                 cf_ldflags_static=no
3056                 ;;
3057         *)
3058                 cf_ldflags_static=yes
3059                 ;;
3060         esac
3061 ],[cf_ldflags_static=no])
3062
3063         rm -f libconftest.*
3064         LIBS="$cf_save_LIBS"
3065
3066         AC_MSG_RESULT($cf_ldflags_static)
3067
3068         if test $cf_ldflags_static != yes
3069         then
3070                 LDFLAGS_STATIC=
3071                 LDFLAGS_SHARED=
3072         fi
3073 else
3074         LDFLAGS_STATIC=
3075         LDFLAGS_SHARED=
3076 fi
3077
3078 AC_SUBST(LDFLAGS_STATIC)
3079 AC_SUBST(LDFLAGS_SHARED)
3080 ])
3081 dnl ---------------------------------------------------------------------------
3082 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
3083 dnl ---------------
3084 dnl For the given system and compiler, find the compiler flags to pass to the
3085 dnl loader to use the "rpath" feature.
3086 AC_DEFUN([CF_LD_RPATH_OPT],
3087 [
3088 AC_REQUIRE([CF_CHECK_CACHE])
3089
3090 LD_RPATH_OPT=
3091 AC_MSG_CHECKING(for an rpath option)
3092 case $cf_cv_system_name in #(vi
3093 irix*) #(vi
3094         if test "$GCC" = yes; then
3095                 LD_RPATH_OPT="-Wl,-rpath,"
3096         else
3097                 LD_RPATH_OPT="-rpath "
3098         fi
3099         ;;
3100 linux*|gnu*|k*bsd*-gnu) #(vi
3101         LD_RPATH_OPT="-Wl,-rpath,"
3102         ;;
3103 openbsd[[2-9]].*|mirbsd*) #(vi
3104         LD_RPATH_OPT="-Wl,-rpath,"
3105         ;;
3106 dragonfly*|freebsd*) #(vi
3107         LD_RPATH_OPT="-rpath "
3108         ;;
3109 netbsd*) #(vi
3110         LD_RPATH_OPT="-Wl,-rpath,"
3111         ;;
3112 osf*|mls+*) #(vi
3113         LD_RPATH_OPT="-rpath "
3114         ;;
3115 solaris2*) #(vi
3116         LD_RPATH_OPT="-R"
3117         ;;
3118 *)
3119         ;;
3120 esac
3121 AC_MSG_RESULT($LD_RPATH_OPT)
3122
3123 case "x$LD_RPATH_OPT" in #(vi
3124 x-R*)
3125         AC_MSG_CHECKING(if we need a space after rpath option)
3126         cf_save_LIBS="$LIBS"
3127         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3128         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3129         LIBS="$cf_save_LIBS"
3130         AC_MSG_RESULT($cf_rpath_space)
3131         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3132         ;;
3133 esac
3134 ])dnl
3135 dnl ---------------------------------------------------------------------------
3136 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
3137 dnl ---------------
3138 dnl Construct a search-list of directories for a nonstandard library-file
3139 dnl
3140 dnl Parameters
3141 dnl     $1 = the variable to return as result
3142 dnl     $2 = the package name
3143 AC_DEFUN([CF_LIBRARY_PATH],
3144 [
3145 $1=
3146 cf_library_path_list=""
3147 if test -n "${LDFLAGS}${LIBS}" ; then
3148         for cf_library_path in $LDFLAGS $LIBS
3149         do
3150                 case $cf_library_path in #(vi
3151                 -L*)
3152                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3153                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3154                         cf_library_path_list="$cf_library_path_list [$]$1"
3155                         ;;
3156                 esac
3157         done
3158 fi
3159
3160 CF_SUBDIR_PATH($1,$2,lib)
3161
3162 $1="$cf_library_path_list [$]$1"
3163 ])dnl
3164 dnl ---------------------------------------------------------------------------
3165 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3166 dnl ------------------
3167 AC_DEFUN([CF_LIBTOOL_VERSION],[
3168 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3169 then
3170         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3171 else
3172         cf_cv_libtool_version=
3173 fi
3174 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3175 ])dnl
3176 dnl ---------------------------------------------------------------------------
3177 dnl CF_LIB_PREFIX version: 9 updated: 2012/01/21 19:28:10
3178 dnl -------------
3179 dnl Compute the library-prefix for the given host system
3180 dnl $1 = variable to set
3181 define([CF_LIB_PREFIX],
3182 [
3183         case $cf_cv_system_name in #(vi
3184         OS/2*|os2*) #(vi
3185         LIB_PREFIX=''
3186         ;;
3187         *)      LIB_PREFIX='lib'
3188         ;;
3189         esac
3190 ifelse($1,,,[$1=$LIB_PREFIX])
3191         AC_SUBST(LIB_PREFIX)
3192 ])dnl
3193 dnl ---------------------------------------------------------------------------
3194 dnl CF_LIB_RULES version: 77 updated: 2015/01/03 11:49:39
3195 dnl ------------
3196 dnl Append definitions and rules for the given models to the subdirectory
3197 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3198 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3199 dnl the corresponding makefile to list the models that we'll generate.
3200 dnl
3201 dnl For shared libraries, make a list of symbolic links to construct when
3202 dnl generating each library.  The convention used for Linux is the simplest
3203 dnl one:
3204 dnl     lib<name>.so    ->
3205 dnl     lib<name>.so.<major>    ->
3206 dnl     lib<name>.so.<maj>.<minor>
3207 dnl
3208 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3209 AC_DEFUN([CF_LIB_RULES],
3210 [
3211 cf_prefix=$LIB_PREFIX
3212 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3213
3214 case $cf_cv_shlib_version in #(vi
3215 cygdll|msysdll|mingw)
3216         TINFO_NAME=$TINFO_ARG_SUFFIX
3217         TINFO_SUFFIX=.dll
3218         ;;
3219 esac
3220
3221 if test -n "$TINFO_SUFFIX" ; then
3222         case $TINFO_SUFFIX in
3223         tw*)
3224                 TINFO_NAME="${TINFO_NAME}tw"
3225                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw//'`
3226                 ;;
3227         t*)
3228                 TINFO_NAME="${TINFO_NAME}t"
3229                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t//'`
3230                 ;;
3231         w*)
3232                 TINFO_NAME="${TINFO_NAME}w"
3233                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w//'`
3234                 ;;
3235         esac
3236 fi
3237
3238 for cf_dir in $SRC_SUBDIRS
3239 do
3240         if test ! -d $srcdir/$cf_dir ; then
3241                 continue
3242         elif test -f $srcdir/$cf_dir/modules; then
3243
3244                 SHARED_LIB=
3245                 Libs_To_Make=
3246
3247                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
3248                 then
3249                         cat >>$cf_dir/Makefile <<CF_EOF
3250
3251 # Generated by CF_LIB_RULES
3252 resulting.map: $UNALTERED_SYMS
3253         sed -e "s/NCURSES\\([[WT]]\\+\\)\?_/NCURSES\\1${cf_cv_abi_version}_/g" < $UNALTERED_SYMS >\[$]@
3254
3255 clean::
3256         rm -f resulting.map
3257 CF_EOF
3258                 fi
3259
3260                 for cf_item in $cf_LIST_MODELS
3261                 do
3262                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3263                         cf_libname=$cf_dir
3264                         test "$cf_dir" = c++ && cf_libname=ncurses++
3265                         if test $cf_item = shared ; then
3266                                 if test -n "${LIB_SUFFIX}"
3267                                 then
3268                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${LIB_SUFFIX}"'//'`
3269                                 else
3270                                         cf_shared_suffix="$cf_suffix"
3271                                 fi
3272                                 if test "$cf_cv_do_symlinks" = yes ; then
3273                                         cf_version_name=
3274
3275                                         case "$cf_cv_shlib_version" in #(vi
3276                                         rel) #(vi
3277                                                 cf_version_name=REL_VERSION
3278                                                 ;;
3279                                         abi)
3280                                                 cf_version_name=ABI_VERSION
3281                                                 ;;
3282                                         esac
3283
3284                                         if test -n "$cf_version_name"
3285                                         then
3286                                                 case "$cf_cv_system_name" in #(vi
3287                                                 darwin*)
3288                                                         # "w", etc?
3289                                                         cf_suffix="${LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3290                                                         ;; #(vi
3291                                                 *)
3292                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3293                                                         ;;
3294                                                 esac
3295                                         fi
3296                                         if test -n "${LIB_SUFFIX}"
3297                                         then
3298                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${LIB_SUFFIX}"'//'`
3299                                         else
3300                                                 cf_shared_suffix="$cf_suffix"
3301                                         fi
3302                                 fi
3303                                 # cygwin needs import library, and has unique naming convention
3304                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3305                                 # use 'cyg' prefix for shared lib.
3306                                 case $cf_cv_shlib_version in #(vi
3307                                 cygdll) #(vi
3308                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3309                                         Libs_To_Make="$Libs_To_Make ../lib/cyg${cf_libname}${cf_cygsuf}"
3310                                         continue
3311                                         ;;
3312                                 msysdll) #(vi
3313                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3314                                         Libs_To_Make="$Libs_To_Make ../lib/msys-${cf_libname}${cf_cygsuf}"
3315                                         continue
3316                                         ;;
3317                                 mingw)
3318                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3319                                         Libs_To_Make="$Libs_To_Make ../lib/lib${cf_libname}${cf_cygsuf}"
3320                                         continue
3321                                         ;;
3322                                 esac
3323                         fi
3324                         Libs_To_Make="$Libs_To_Make ../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3325                 done
3326
3327                 if test $cf_dir = ncurses ; then
3328                         cf_subsets="$LIB_SUBSETS"
3329                         cf_r_parts="$cf_subsets"
3330                         cf_liblist="$Libs_To_Make"
3331
3332                         while test -n "$cf_r_parts"
3333                         do
3334                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3335                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3336                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3337                                         cf_item=
3338                                         case $cf_l_parts in #(vi
3339                                         *termlib*) #(vi
3340                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3341                                                 ;;
3342                                         *ticlib*)
3343                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3344                                                 ;;
3345                                         *)
3346                                                 break
3347                                                 ;;
3348                                         esac
3349                                         if test -n "$cf_item"; then
3350                                                 Libs_To_Make="$cf_item $Libs_To_Make"
3351                                         fi
3352                                 else
3353                                         break
3354                                 fi
3355                         done
3356                 else
3357                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3358                 fi
3359
3360                 if test $cf_dir = c++; then
3361                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3362                                 cf_list=
3363                                 for cf_item in $Libs_To_Make
3364                                 do
3365                                         case $cf_item in
3366                                         *.a)
3367                                                 ;;
3368                                         *)
3369                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3370                                                 ;;
3371                                         esac
3372                                         for cf_test in $cf_list
3373                                         do
3374                                                 if test "$cf_test" = "$cf_item"
3375                                                 then
3376                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3377                                                         cf_item=
3378                                                         break
3379                                                 fi
3380                                         done
3381                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3382                                 done
3383                                 Libs_To_Make="$cf_list"
3384                         fi
3385                 fi
3386
3387                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3388                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3389                         $cf_dir/Makefile >$cf_dir/Makefile.out
3390                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3391
3392                 $AWK -f $srcdir/mk-0th.awk \
3393                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3394                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3395
3396                 for cf_subset in $cf_subsets
3397                 do
3398                         cf_subdirs=
3399                         for cf_item in $cf_LIST_MODELS
3400                         do
3401
3402                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3403                         CF_UPPER(cf_ITEM,$cf_item)
3404
3405                         CXX_MODEL=$cf_ITEM
3406                         if test "$CXX_MODEL" = SHARED; then
3407                                 case $cf_cv_shlib_version in #(vi
3408                                 cygdll|msysdll|mingw) #(vi
3409                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3410                                         with_shared_cxx=yes
3411                                         ;;
3412                                 *)
3413                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3414                                         ;;
3415                                 esac
3416                         fi
3417
3418                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3419                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3420
3421                         # Test for case where we build libtinfo with a different name.
3422                         cf_libname=$cf_dir
3423                         if test $cf_dir = ncurses ; then
3424                                 case $cf_subset in
3425                                 *base*)
3426                                         cf_libname=${cf_libname}$LIB_SUFFIX
3427                                         ;;
3428                                 *termlib*)
3429                                         cf_libname=$TINFO_LIB_SUFFIX
3430                                         ;;
3431                                 ticlib*)
3432                                         cf_libname=$TICS_LIB_SUFFIX
3433                                         ;;
3434                                 esac
3435                         elif test $cf_dir = c++ ; then
3436                                 cf_libname=ncurses++$LIB_SUFFIX
3437                         else
3438                                 cf_libname=${cf_libname}$LIB_SUFFIX
3439                         fi
3440                         if test -n "${DFT_ARG_SUFFIX}" ; then
3441                                 # undo $LIB_SUFFIX add-on in CF_LIB_SUFFIX
3442                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${LIB_SUFFIX}%%"`
3443                         fi
3444
3445                         # These dependencies really are for development, not
3446                         # builds, but they are useful in porting, too.
3447                         cf_depend="../include/ncurses_cfg.h"
3448                         if test "$srcdir" = "."; then
3449                                 cf_reldir="."
3450                         else
3451                                 cf_reldir="\${srcdir}"
3452                         fi
3453
3454                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3455                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3456                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3457                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3458                         fi
3459
3460                         cf_dir_suffix=
3461                         old_cf_suffix="$cf_suffix"
3462                         if test "$cf_cv_shlib_version_infix" = yes ; then
3463                         if test -n "$LIB_SUFFIX" ; then
3464                                 case $LIB_SUFFIX in
3465                                 tw*)
3466                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
3467                                         cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3468                                         cf_dir_suffix=tw
3469                                         ;;
3470                                 t*)
3471                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
3472                                         cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3473                                         cf_dir_suffix=t
3474                                         ;;
3475                                 w*)
3476                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
3477                                         cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3478                                         cf_dir_suffix=w
3479                                         ;;
3480                                 esac
3481                         fi
3482                         fi
3483
3484                         $AWK -f $srcdir/mk-1st.awk \
3485                                 name=${cf_libname}${cf_dir_suffix} \
3486                                 traces=$LIB_TRACING \
3487                                 MODEL=$cf_ITEM \
3488                                 CXX_MODEL=$CXX_MODEL \
3489                                 model=$cf_subdir \
3490                                 prefix=$cf_prefix \
3491                                 suffix=$cf_suffix \
3492                                 subset=$cf_subset \
3493                                 driver=$cf_cv_term_driver \
3494                                 SymLink="$LN_S" \
3495                                 TermlibRoot=$TINFO_NAME \
3496                                 TermlibSuffix=$TINFO_SUFFIX \
3497                                 ShlibVer=$cf_cv_shlib_version \
3498                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3499                                 ReLink=${cf_cv_do_relink:-no} \
3500                                 DoLinks=$cf_cv_do_symlinks \
3501                                 rmSoLocs=$cf_cv_rm_so_locs \
3502                                 ldconfig="$LDCONFIG" \
3503                                 overwrite=$WITH_OVERWRITE \
3504                                 depend="$cf_depend" \
3505                                 host="$host" \
3506                                 libtool_version="$LIBTOOL_VERSION" \
3507                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3508
3509                         cf_suffix="$old_cf_suffix"
3510
3511                         for cf_subdir2 in $cf_subdirs lib
3512                         do
3513                                 test $cf_subdir = $cf_subdir2 && break
3514                         done
3515                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3516                         $AWK -f $srcdir/mk-2nd.awk \
3517                                 name=$cf_dir \
3518                                 traces=$LIB_TRACING \
3519                                 MODEL=$cf_ITEM \
3520                                 model=$cf_subdir \
3521                                 subset=$cf_subset \
3522                                 srcdir=$srcdir \
3523                                 echo=$WITH_ECHO \
3524                                 crenames=$cf_cv_prog_CC_c_o \
3525                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3526                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3527                         cf_subdirs="$cf_subdirs $cf_subdir"
3528                         done
3529                 done
3530         fi
3531
3532         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
3533 done
3534
3535 for cf_dir in $SRC_SUBDIRS
3536 do
3537         if test ! -d $srcdir/$cf_dir ; then
3538                 continue
3539         fi
3540
3541         if test -f $cf_dir/Makefile ; then
3542                 case "$cf_dir" in
3543                 Ada95) #(vi
3544                         echo 'libs \' >> Makefile
3545                         echo 'install.libs \' >> Makefile
3546                         echo 'uninstall.libs ::' >> Makefile
3547                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
3548                         ;;
3549                 esac
3550         fi
3551
3552         if test -f $srcdir/$cf_dir/modules; then
3553                 echo >> Makefile
3554                 if test -f $srcdir/$cf_dir/headers; then
3555 cat >> Makefile <<CF_EOF
3556 install.includes \\
3557 uninstall.includes \\
3558 CF_EOF
3559                 fi
3560 if test "$cf_dir" != "c++" ; then
3561 echo 'lint \' >> Makefile
3562 fi
3563 cat >> Makefile <<CF_EOF
3564 libs \\
3565 lintlib \\
3566 install.libs \\
3567 uninstall.libs \\
3568 install.$cf_dir \\
3569 uninstall.$cf_dir ::
3570         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3571 CF_EOF
3572         elif test -f $srcdir/$cf_dir/headers; then
3573 cat >> Makefile <<CF_EOF
3574
3575 libs \\
3576 install.libs \\
3577 uninstall.libs \\
3578 install.includes \\
3579 uninstall.includes ::
3580         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3581 CF_EOF
3582 fi
3583 done
3584
3585 if test "x$cf_with_db_install" = xyes; then
3586 cat >> Makefile <<CF_EOF
3587
3588 install.libs uninstall.libs \\
3589 install.data uninstall.data ::
3590 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3591 CF_EOF
3592 else
3593 cat >> Makefile <<CF_EOF
3594
3595 install.libs uninstall.libs ::
3596         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3597 CF_EOF
3598 fi
3599
3600 if test "x$cf_with_manpages" = xyes; then
3601 cat >> Makefile <<CF_EOF
3602
3603 install.man \\
3604 uninstall.man ::
3605         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
3606 CF_EOF
3607 fi
3608
3609 cat >> Makefile <<CF_EOF
3610
3611 distclean ::
3612         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3613         rm -f headers.sh headers.sed mk_shared_lib.sh
3614         rm -f edit_man.* man_alias.*
3615         rm -rf \${DIRS_TO_MAKE}
3616 CF_EOF
3617
3618 # Special case: tack's manpage lives in its own directory.
3619 if test "x$cf_with_manpages" = xyes; then
3620 if test -d tack ; then
3621 if test -f $srcdir/$tack.h; then
3622 cat >> Makefile <<CF_EOF
3623
3624 install.man \\
3625 uninstall.man ::
3626         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
3627 CF_EOF
3628 fi
3629 fi
3630 fi
3631
3632 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3633 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3634 dnl anything, and will make it more standardized.  It's awkward to decide this
3635 dnl at configuration because of quoting, so we'll simply make all headers
3636 dnl installed via a script that can do the right thing.
3637
3638 rm -f headers.sed headers.sh
3639
3640 dnl ( generating this script makes the makefiles a little tidier :-)
3641 echo creating headers.sh
3642 cat >headers.sh <<CF_EOF
3643 #! /bin/sh
3644 # This shell script is generated by the 'configure' script.  It is invoked in a
3645 # subdirectory of the build tree.  It generates a sed-script in the parent
3646 # directory that is used to adjust includes for header files that reside in a
3647 # subdirectory of /usr/include, etc.
3648 PRG=""
3649 while test \[$]# != 3
3650 do
3651 PRG="\$PRG \[$]1"; shift
3652 done
3653 DST=\[$]1
3654 REF=\[$]2
3655 SRC=\[$]3
3656 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3657 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3658 echo installing \$SRC in \$DST
3659 CF_EOF
3660
3661 if test $WITH_CURSES_H = yes; then
3662         cat >>headers.sh <<CF_EOF
3663 case \$DST in
3664 /*/include/*)
3665         END=\`basename \$DST\`
3666         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3667         do
3668                 NAME=\`basename \$i\`
3669                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3670         done
3671         ;;
3672 *)
3673         echo "" >> \$TMPSED
3674         ;;
3675 esac
3676 CF_EOF
3677
3678 else
3679         cat >>headers.sh <<CF_EOF
3680 case \$DST in
3681 /*/include/*)
3682         END=\`basename \$DST\`
3683         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3684         do
3685                 NAME=\`basename \$i\`
3686                 if test "\$NAME" = "curses.h"
3687                 then
3688                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3689                         NAME=ncurses.h
3690                 fi
3691                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3692         done
3693         ;;
3694 *)
3695         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3696         ;;
3697 esac
3698 CF_EOF
3699 fi
3700 cat >>headers.sh <<CF_EOF
3701 rm -f \$TMPSRC
3702 sed -f \$TMPSED \$SRC > \$TMPSRC
3703 NAME=\`basename \$SRC\`
3704 CF_EOF
3705 if test $WITH_CURSES_H != yes; then
3706         cat >>headers.sh <<CF_EOF
3707 test "\$NAME" = "curses.h" && NAME=ncurses.h
3708 CF_EOF
3709 fi
3710 cat >>headers.sh <<CF_EOF
3711 # Just in case someone gzip'd manpages, remove the conflicting copy.
3712 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3713
3714 eval \$PRG \$TMPSRC \$DST/\$NAME
3715 rm -f \$TMPSRC \$TMPSED
3716 CF_EOF
3717
3718 chmod 0755 headers.sh
3719
3720 for cf_dir in $SRC_SUBDIRS
3721 do
3722         if test ! -d $srcdir/$cf_dir ; then
3723                 continue
3724         fi
3725
3726         if test -f $srcdir/$cf_dir/headers; then
3727                 $AWK -f $srcdir/mk-hdr.awk \
3728                         subset="$LIB_SUBSETS" \
3729                         compat="$WITH_CURSES_H" \
3730                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3731         fi
3732
3733         if test -f $srcdir/$cf_dir/modules; then
3734                 if test "$cf_dir" != "c++" ; then
3735                         cat >>$cf_dir/Makefile <<"CF_EOF"
3736 depend : ${AUTO_SRC}
3737         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3738
3739 # DO NOT DELETE THIS LINE -- make depend depends on it.
3740 CF_EOF
3741                 fi
3742         fi
3743 done
3744 AC_SUBST(Libs_To_Make)
3745 ])dnl
3746 dnl ---------------------------------------------------------------------------
3747 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3748 dnl -------------
3749 dnl Find the and soname for the given shared library.  Set the cache variable
3750 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3751 dnl variable to "unknown".
3752 dnl
3753 dnl $1 = headers
3754 dnl $2 = code
3755 dnl $3 = library name
3756 AC_DEFUN([CF_LIB_SONAME],
3757 [
3758 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3759
3760 cf_cv_$3_soname=unknown
3761 if test "$cross_compiling" != yes ; then
3762 cat >conftest.$ac_ext <<CF_EOF
3763 $1
3764 int main()
3765 {
3766 $2
3767         ${cf_cv_main_return:-return}(0);
3768 }
3769 CF_EOF
3770 cf_save_LIBS="$LIBS"
3771         CF_ADD_LIB($3)
3772         if AC_TRY_EVAL(ac_compile) ; then
3773                 if AC_TRY_EVAL(ac_link) ; then
3774                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3775                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3776                 fi
3777         fi
3778 rm -rf conftest*
3779 LIBS="$cf_save_LIBS"
3780 fi
3781 ])
3782 ])
3783 dnl ---------------------------------------------------------------------------
3784 dnl CF_LIB_SUFFIX version: 23 updated: 2014/06/21 17:47:12
3785 dnl -------------
3786 dnl Compute the library file-suffix from the given model name
3787 dnl $1 = model name
3788 dnl $2 = variable to set (the nominal library suffix)
3789 dnl $3 = dependency variable to set (actual filename)
3790 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3791 AC_DEFUN([CF_LIB_SUFFIX],
3792 [
3793         case X$1 in #(vi
3794         Xlibtool) #(vi
3795                 $2='.la'
3796                 $3=[$]$2
3797                 ;;
3798         Xdebug) #(vi
3799                 $2='_g.a'
3800                 $3=[$]$2
3801                 ;;
3802         Xprofile) #(vi
3803                 $2='_p.a'
3804                 $3=[$]$2
3805                 ;;
3806         Xshared) #(vi
3807                 case $cf_cv_system_name in
3808                 aix[[5-7]]*) #(vi
3809                         $2='.so'
3810                         $3=[$]$2
3811                         ;;
3812                 cygwin*|msys*|mingw*) #(vi
3813                         $2='.dll'
3814                         $3='.dll.a'
3815                         ;;
3816                 darwin*) #(vi
3817                         $2='.dylib'
3818                         $3=[$]$2
3819                         ;;
3820                 hpux*) #(vi
3821                         case $target in
3822                         ia64*) #(vi
3823                                 $2='.so'
3824                                 $3=[$]$2
3825                                 ;;
3826                         *) #(vi
3827                                 $2='.sl'
3828                                 $3=[$]$2
3829                                 ;;
3830                         esac
3831                         ;;
3832                 *) #(vi
3833                         $2='.so'
3834                         $3=[$]$2
3835                         ;;
3836                 esac
3837                 ;;
3838         *)
3839                 $2='.a'
3840                 $3=[$]$2
3841                 ;;
3842         esac
3843         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3844         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
3845 ])dnl
3846 dnl ---------------------------------------------------------------------------
3847 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
3848 dnl -----------
3849 dnl Compute the string to append to -library from the given model name
3850 dnl $1 = model name
3851 dnl $2 = variable to set
3852 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3853 AC_DEFUN([CF_LIB_TYPE],
3854 [
3855         case $1 in
3856         libtool) $2=''   ;;
3857         normal)  $2=''   ;;
3858         debug)   $2='_g' ;;
3859         profile) $2='_p' ;;
3860         shared)  $2=''   ;;
3861         esac
3862         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3863 ])dnl
3864 dnl ---------------------------------------------------------------------------
3865 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
3866 dnl ----------------
3867 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3868 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3869 dnl have to provide wrappers for global tables to ensure they're linked
3870 dnl properly.
3871 AC_DEFUN([CF_LINK_DATAONLY],
3872 [
3873 AC_MSG_CHECKING([if data-only library module links])
3874 AC_CACHE_VAL(cf_cv_link_dataonly,[
3875         rm -f conftest.a
3876         cat >conftest.$ac_ext <<EOF
3877 #line __oline__ "configure"
3878 int     testdata[[3]] = { 123, 456, 789 };
3879 EOF
3880         if AC_TRY_EVAL(ac_compile) ; then
3881                 mv conftest.o data.o && \
3882                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3883         fi
3884         rm -f conftest.$ac_ext data.o
3885         cat >conftest.$ac_ext <<EOF
3886 #line __oline__ "configure"
3887 int     testfunc()
3888 {
3889 #if defined(NeXT)
3890         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3891 #else
3892         extern int testdata[[3]];
3893         return testdata[[0]] == 123
3894            &&  testdata[[1]] == 456
3895            &&  testdata[[2]] == 789;
3896 #endif
3897 }
3898 EOF
3899         if AC_TRY_EVAL(ac_compile); then
3900                 mv conftest.o func.o && \
3901                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3902         fi
3903         rm -f conftest.$ac_ext func.o
3904         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3905         cf_saveLIBS="$LIBS"
3906         LIBS="conftest.a $LIBS"
3907         AC_TRY_RUN([
3908         int main()
3909         {
3910                 extern int testfunc();
3911                 ${cf_cv_main_return:-return} (!testfunc());
3912         }
3913         ],
3914         [cf_cv_link_dataonly=yes],
3915         [cf_cv_link_dataonly=no],
3916         [cf_cv_link_dataonly=unknown])
3917         LIBS="$cf_saveLIBS"
3918         ])
3919 AC_MSG_RESULT($cf_cv_link_dataonly)
3920
3921 if test "$cf_cv_link_dataonly" = no ; then
3922         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
3923         BROKEN_LINKER=1
3924 fi
3925
3926 ])dnl
3927 dnl ---------------------------------------------------------------------------
3928 dnl CF_LINK_FUNCS version: 8 updated: 2012/10/06 17:56:13
3929 dnl -------------
3930 dnl Most Unix systems have both link and symlink, a few don't have symlink.
3931 dnl A few non-Unix systems implement symlink, but not link.
3932 dnl A few non-systems implement neither (or have nonfunctional versions).
3933 AC_DEFUN([CF_LINK_FUNCS],
3934 [
3935 AC_CHECK_FUNCS( \
3936         remove \
3937         unlink )
3938
3939 if test "$cross_compiling" = yes ; then
3940         AC_CHECK_FUNCS( \
3941                 link \
3942                 symlink )
3943 else
3944         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
3945                 cf_cv_link_funcs=
3946                 for cf_func in link symlink ; do
3947                         AC_TRY_RUN([
3948 #include <sys/types.h>
3949 #include <sys/stat.h>
3950 #ifdef HAVE_UNISTD_H
3951 #include <unistd.h>
3952 #endif
3953 int main()
3954 {
3955         int fail = 0;
3956         char *src = "config.log";
3957         char *dst = "conftest.chk";
3958         struct stat src_sb;
3959         struct stat dst_sb;
3960
3961         stat(src, &src_sb);
3962         fail = ($cf_func("config.log", "conftest.chk") < 0)
3963             || (stat(dst, &dst_sb) < 0)
3964             || (dst_sb.st_mtime != src_sb.st_mtime);
3965 #ifdef HAVE_UNLINK
3966         unlink(dst);
3967 #else
3968         remove(dst);
3969 #endif
3970         ${cf_cv_main_return:-return} (fail);
3971 }
3972                         ],[
3973                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
3974                         eval 'ac_cv_func_'$cf_func'=yes'],[
3975                         eval 'ac_cv_func_'$cf_func'=no'],[
3976                         eval 'ac_cv_func_'$cf_func'=error'])
3977                 done
3978                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
3979         ])
3980         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
3981         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
3982 fi
3983 ])dnl
3984 dnl ---------------------------------------------------------------------------
3985 dnl CF_MAKEFLAGS version: 15 updated: 2014/05/10 16:43:23
3986 dnl ------------
3987 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
3988 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
3989 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
3990 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
3991 AC_DEFUN([CF_MAKEFLAGS],
3992 [
3993 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
3994         cf_cv_makeflags=''
3995         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
3996         do
3997                 cat >cf_makeflags.tmp <<CF_EOF
3998 SHELL = /bin/sh
3999 all :
4000         @ echo '.$cf_option'
4001 CF_EOF
4002                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
4003                 case "$cf_result" in
4004                 .*k|.*kw)
4005                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
4006                         case "$cf_result" in
4007                         .*CC=*) cf_cv_makeflags=
4008                                 ;;
4009                         *)      cf_cv_makeflags=$cf_option
4010                                 ;;
4011                         esac
4012                         break
4013                         ;;
4014                 .-)     ;;
4015                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
4016                         ;;
4017                 esac
4018         done
4019         rm -f cf_makeflags.tmp
4020 ])
4021
4022 AC_SUBST(cf_cv_makeflags)
4023 ])dnl
4024 dnl ---------------------------------------------------------------------------
4025 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
4026 dnl ------------
4027 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
4028 dnl a monocase filesystem.
4029 AC_DEFUN([CF_MAKE_TAGS],[
4030 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
4031
4032 AC_CHECK_PROGS(CTAGS, exctags ctags)
4033 AC_CHECK_PROGS(ETAGS, exetags etags)
4034
4035 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
4036
4037 if test "$cf_cv_mixedcase" = yes ; then
4038         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
4039 else
4040         MAKE_UPPER_TAGS=no
4041 fi
4042
4043 if test "$MAKE_UPPER_TAGS" = yes ; then
4044         MAKE_UPPER_TAGS=
4045 else
4046         MAKE_UPPER_TAGS="#"
4047 fi
4048
4049 if test "$MAKE_LOWER_TAGS" = yes ; then
4050         MAKE_LOWER_TAGS=
4051 else
4052         MAKE_LOWER_TAGS="#"
4053 fi
4054
4055 AC_SUBST(CTAGS)
4056 AC_SUBST(ETAGS)
4057
4058 AC_SUBST(MAKE_UPPER_TAGS)
4059 AC_SUBST(MAKE_LOWER_TAGS)
4060 ])dnl
4061 dnl ---------------------------------------------------------------------------
4062 dnl CF_MANPAGE_FORMAT version: 9 updated: 2010/10/23 16:10:30
4063 dnl -----------------
4064 dnl Option to allow user to override automatic configuration of manpage format.
4065 dnl There are several special cases:
4066 dnl
4067 dnl     gzip - man checks for, can display gzip'd files
4068 dnl     compress - man checks for, can display compressed files
4069 dnl     BSDI - files in the cat-directories are suffixed ".0"
4070 dnl     formatted - installer should format (put files in cat-directory)
4071 dnl     catonly - installer should only format, e.g., for a turnkey system.
4072 dnl
4073 dnl There are other configurations which this macro does not test, e.g., HPUX's
4074 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
4075 dnl convention would not match our use).
4076 AC_DEFUN([CF_MANPAGE_FORMAT],
4077 [
4078 AC_REQUIRE([CF_PATHSEP])
4079 AC_MSG_CHECKING(format of man-pages)
4080
4081 AC_ARG_WITH(manpage-format,
4082         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
4083                           optionally formatted/catonly, e.g., gzip,formatted],
4084         [MANPAGE_FORMAT=$withval],
4085         [MANPAGE_FORMAT=unknown])
4086
4087 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
4088 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
4089
4090 cf_unknown=
4091
4092 case $MANPAGE_FORMAT in
4093 unknown)
4094   if test -z "$MANPATH" ; then
4095     MANPATH="/usr/man:/usr/share/man"
4096   fi
4097
4098   # look for the 'date' man-page (it's most likely to be installed!)
4099   MANPAGE_FORMAT=
4100   cf_preform=no
4101   cf_catonly=yes
4102   cf_example=date
4103
4104   IFS="${IFS:-  }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
4105   for cf_dir in $MANPATH; do
4106     test -z "$cf_dir" && cf_dir=/usr/man
4107     for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
4108     do
4109       cf_test=`echo $cf_name | sed -e 's/*//'`
4110       if test "x$cf_test" = "x$cf_name" ; then
4111
4112         case "$cf_name" in
4113         *.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
4114         *.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
4115         *.0)    MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
4116         *)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
4117         esac
4118
4119         case "$cf_name" in
4120         $cf_dir/man*)
4121           cf_catonly=no
4122           ;;
4123         $cf_dir/cat*)
4124           cf_preform=yes
4125           ;;
4126         esac
4127         break
4128       fi
4129
4130       # if we found a match in either man* or cat*, stop looking
4131       if test -n "$MANPAGE_FORMAT" ; then
4132         cf_found=no
4133         test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
4134         test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
4135         case "$cf_name" in
4136         $cf_dir/cat*)
4137           cf_found=yes
4138           ;;
4139         esac
4140         test $cf_found=yes && break
4141       fi
4142     done
4143     # only check the first directory in $MANPATH where we find manpages
4144     if test -n "$MANPAGE_FORMAT" ; then
4145        break
4146     fi
4147   done
4148   # if we did not find the example, just assume it is normal
4149   test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
4150   IFS="$ac_save_ifs"
4151   ;;
4152 *)
4153   for cf_option in $MANPAGE_FORMAT; do
4154      case $cf_option in #(vi
4155      gzip|compress|BSDI|normal|formatted|catonly)
4156        ;;
4157      *)
4158        cf_unknown="$cf_unknown $cf_option"
4159        ;;
4160      esac
4161   done
4162   ;;
4163 esac
4164
4165 AC_MSG_RESULT($MANPAGE_FORMAT)
4166 if test -n "$cf_unknown" ; then
4167   AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
4168 fi
4169 ])dnl
4170 dnl ---------------------------------------------------------------------------
4171 dnl CF_MANPAGE_RENAMES version: 7 updated: 2005/06/18 18:51:57
4172 dnl ------------------
4173 dnl The Debian people have their own naming convention for manpages.  This
4174 dnl option lets us override the name of the file containing renaming, or
4175 dnl disable it altogether.
4176 AC_DEFUN([CF_MANPAGE_RENAMES],
4177 [
4178 AC_MSG_CHECKING(for manpage renaming)
4179
4180 AC_ARG_WITH(manpage-renames,
4181         [  --with-manpage-renames  specify manpage-renaming],
4182         [MANPAGE_RENAMES=$withval],
4183         [MANPAGE_RENAMES=yes])
4184
4185 case ".$MANPAGE_RENAMES" in #(vi
4186 .no) #(vi
4187   ;;
4188 .|.yes)
4189   # Debian 'man' program?
4190   if test -f /etc/debian_version ; then
4191     MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
4192   else
4193     MANPAGE_RENAMES=no
4194   fi
4195   ;;
4196 esac
4197
4198 if test "$MANPAGE_RENAMES" != no ; then
4199   if test -f $srcdir/man/$MANPAGE_RENAMES ; then
4200     MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
4201   elif test ! -f $MANPAGE_RENAMES ; then
4202     AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
4203   fi
4204
4205   test ! -d man && mkdir man
4206
4207   # Construct a sed-script to perform renaming within man-pages
4208   if test -n "$MANPAGE_RENAMES" ; then
4209     test ! -d man && mkdir man
4210     sh $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
4211   fi
4212 fi
4213
4214 AC_MSG_RESULT($MANPAGE_RENAMES)
4215 AC_SUBST(MANPAGE_RENAMES)
4216 ])dnl
4217 dnl ---------------------------------------------------------------------------
4218 dnl CF_MANPAGE_SYMLINKS version: 5 updated: 2010/07/24 17:12:40
4219 dnl -------------------
4220 dnl Some people expect each tool to make all aliases for manpages in the
4221 dnl man-directory.  This accommodates the older, less-capable implementations
4222 dnl of 'man', and is optional.
4223 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4224 [
4225 AC_MSG_CHECKING(if manpage aliases will be installed)
4226
4227 AC_ARG_WITH(manpage-aliases,
4228         [  --with-manpage-aliases  specify manpage-aliases using .so],
4229         [MANPAGE_ALIASES=$withval],
4230         [MANPAGE_ALIASES=yes])
4231
4232 AC_MSG_RESULT($MANPAGE_ALIASES)
4233
4234 case "x$LN_S" in #(vi
4235 xln*) #(vi
4236         cf_use_symlinks=yes
4237         ;;
4238 *)
4239         cf_use_symlinks=no
4240         ;;
4241 esac
4242
4243 MANPAGE_SYMLINKS=no
4244 if test "$MANPAGE_ALIASES" = yes ; then
4245 AC_MSG_CHECKING(if manpage symlinks should be used)
4246
4247 AC_ARG_WITH(manpage-symlinks,
4248         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
4249         [MANPAGE_SYMLINKS=$withval],
4250         [MANPAGE_SYMLINKS=$cf_use_symlinks])
4251
4252 if test "$$cf_use_symlinks" = no; then
4253 if test "$MANPAGE_SYMLINKS" = yes ; then
4254         AC_MSG_WARN(cannot make symlinks, will use .so files)
4255         MANPAGE_SYMLINKS=no
4256 fi
4257 fi
4258
4259 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4260 fi
4261
4262 ])dnl
4263 dnl ---------------------------------------------------------------------------
4264 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4265 dnl --------------
4266 dnl This option causes manpages to be run through tbl(1) to generate tables
4267 dnl correctly.
4268 AC_DEFUN([CF_MANPAGE_TBL],
4269 [
4270 AC_MSG_CHECKING(for manpage tbl)
4271
4272 AC_ARG_WITH(manpage-tbl,
4273         [  --with-manpage-tbl      specify manpage processing with tbl],
4274         [MANPAGE_TBL=$withval],
4275         [MANPAGE_TBL=no])
4276
4277 AC_MSG_RESULT($MANPAGE_TBL)
4278 ])dnl
4279 dnl ---------------------------------------------------------------------------
4280 dnl CF_MAN_PAGES version: 43 updated: 2013/02/09 12:53:45
4281 dnl ------------
4282 dnl Try to determine if the man-pages on the system are compressed, and if
4283 dnl so, what format is used.  Use this information to construct a script that
4284 dnl will install man-pages.
4285 AC_DEFUN([CF_MAN_PAGES],
4286 [
4287 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4288 CF_MANPAGE_FORMAT
4289 CF_MANPAGE_RENAMES
4290 CF_MANPAGE_SYMLINKS
4291 CF_MANPAGE_TBL
4292
4293   if test "$prefix" = "NONE" ; then
4294      cf_prefix="$ac_default_prefix"
4295   else
4296      cf_prefix="$prefix"
4297   fi
4298
4299   case "$MANPAGE_FORMAT" in # (vi
4300   *catonly*) # (vi
4301     cf_format=yes
4302     cf_inboth=no
4303     ;;
4304   *formatted*) # (vi
4305     cf_format=yes
4306     cf_inboth=yes
4307     ;;
4308   *)
4309     cf_format=no
4310     cf_inboth=no
4311     ;;
4312   esac
4313
4314 test ! -d man && mkdir man
4315
4316 cf_so_strip=
4317 cf_compress=
4318 case "$MANPAGE_FORMAT" in #(vi
4319 *compress*) #(vi
4320         cf_so_strip="Z"
4321         cf_compress=compress
4322   ;;
4323 *gzip*)
4324         cf_so_strip="gz"
4325         cf_compress=gzip
4326   ;;
4327 esac
4328
4329 cf_edit_man=./edit_man.sh
4330 cf_man_alias=`pwd`/man_alias.sed
4331
4332 cat >$cf_edit_man <<CF_EOF
4333 #! /bin/sh
4334 # this script is generated by the configure-script CF_MAN_PAGES macro.
4335
4336 prefix="$cf_prefix"
4337 datarootdir="$datarootdir"
4338 datadir="$datadir"
4339
4340 NCURSES_MAJOR="$NCURSES_MAJOR"
4341 NCURSES_MINOR="$NCURSES_MINOR"
4342 NCURSES_PATCH="$NCURSES_PATCH"
4343
4344 NCURSES_OSPEED="$NCURSES_OSPEED"
4345 TERMINFO="$TERMINFO"
4346
4347 INSTALL="$INSTALL"
4348 INSTALL_DATA="$INSTALL_DATA"
4349
4350 transform="$program_transform_name"
4351
4352 TMP=\${TMPDIR:=/tmp}/man\$\$
4353 trap "rm -f \$TMP" 0 1 2 5 15
4354
4355 form=\[$]1
4356 shift || exit 1
4357
4358 verb=\[$]1
4359 shift || exit 1
4360
4361 mandir=\[$]1
4362 shift || exit 1
4363
4364 srcdir=\[$]1
4365 top_srcdir=\[$]srcdir/..
4366 shift || exit 1
4367
4368 if test "\$form" = normal ; then
4369         if test "$cf_format" = yes ; then
4370         if test "$cf_inboth" = no ; then
4371                 sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4372                 exit $?
4373         fi
4374         fi
4375         cf_subdir=\$mandir/man
4376         cf_tables=$MANPAGE_TBL
4377 else
4378         cf_subdir=\$mandir/cat
4379         cf_tables=yes
4380 fi
4381
4382 # process the list of source-files
4383 for i in \[$]* ; do
4384 case \$i in #(vi
4385 *.orig|*.rej) ;; #(vi
4386 *.[[0-9]]*)
4387         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4388         if test \$verb = installing ; then
4389         if test ! -d \$cf_subdir\${section} ; then
4390                 mkdir -p \$cf_subdir\$section
4391         fi
4392         fi
4393
4394         # replace variables in man page
4395         if test ! -f $cf_man_alias ; then
4396 cat >>$cf_man_alias <<-CF_EOF2
4397                 s,@DATADIR@,\$datadir,g
4398                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
4399                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
4400                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
4401                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
4402                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
4403                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
4404 CF_EOF
4405         ifelse($1,,,[
4406         for cf_name in $1
4407         do
4408                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4409                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4410 cat >>$cf_edit_man <<-CF_EOF
4411                 s,@$cf_NAME@,$cf_name,g
4412 CF_EOF
4413         done
4414         ])
4415 cat >>$cf_edit_man <<CF_EOF
4416 CF_EOF2
4417                 echo "...made $cf_man_alias"
4418         fi
4419
4420         aliases=
4421         cf_source=\`basename \$i\`
4422         inalias=\$cf_source
4423         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4424         if test ! -f \$inalias ; then
4425                 echo .. skipped \$cf_source
4426                 continue
4427         fi
4428 CF_EOF
4429
4430 if test "$MANPAGE_ALIASES" != no ; then
4431 cat >>$cf_edit_man <<CF_EOF
4432         nCurses=ignore.3x
4433         test $with_curses_h = yes && nCurses=ncurses.3x
4434         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4435 CF_EOF
4436 fi
4437
4438 if test "$MANPAGE_RENAMES" = no ; then
4439 cat >>$cf_edit_man <<CF_EOF