aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2022,2023 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: aclocal.m4,v 1.1062 2023/12/04 00:39:37 tom Exp $
  33 dnl Macros used in NCURSES auto-configuration script.
  34 dnl
  35 dnl These macros are maintained separately from NCURSES.  The copyright on
  36 dnl this file applies to the aggregation of macros and does not affect use of
  37 dnl these macros in other applications.
  38 dnl
  39 dnl See these pages for additional information:
  40 dnl             https://invisible-island.net/autoconf/
  41 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  42 dnl
  43 dnl ---------------------------------------------------------------------------
  44 dnl ---------------------------------------------------------------------------
  45 dnl AM_LANGINFO_CODESET version: 7 updated: 2023/01/11 04:05:23
  46 dnl -------------------
  47 dnl Inserted as requested by gettext 0.10.40
  48 dnl File from /usr/share/aclocal
  49 dnl codeset.m4
  50 dnl ====================
  51 dnl serial AM1
  52 dnl
  53 dnl From Bruno Haible.
  54 AC_DEFUN([AM_LANGINFO_CODESET],
  55 [
  56 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  57         [AC_TRY_LINK([
  58 $ac_includes_default
  59 #include <langinfo.h>],
  60         [char* cs = nl_langinfo(CODESET); (void)cs],
  61         am_cv_langinfo_codeset=yes,
  62         am_cv_langinfo_codeset=no)
  63         ])
  64         if test "$am_cv_langinfo_codeset" = yes; then
  65                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  66                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  67         fi
  68 ])dnl
  69 dnl ---------------------------------------------------------------------------
  70 dnl CF_ABI_DEFAULTS version: 5 updated: 2023/10/21 08:54:23
  71 dnl ---------------
  72 dnl Provide configure-script defaults for different ncurses ABIs.
  73 AC_DEFUN([CF_ABI_DEFAULTS],[
  74 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  75
  76 # ABI 5 defaults:
  77 cf_dft_ccharw_max=5
  78 cf_dft_chtype=auto
  79 cf_dft_ext_colors=no
  80 cf_dft_ext_const=no
  81 cf_dft_ext_mouse=no
  82 cf_dft_ext_putwin=no
  83 cf_dft_ext_spfuncs=no
  84 cf_dft_filter_syms=no
  85 cf_dft_interop=no
  86 cf_dft_mmask_t=auto
  87 cf_dft_opaque_curses=no
  88 cf_dft_ordinate_type=short
  89 cf_dft_signed_char=no
  90 cf_dft_tparm_arg=long
  91 cf_dft_widec=no
  92 cf_dft_with_lp64=no
  93
  94 # ABI 6 default differences from ABI 5:
  95 case x$cf_cv_abi_default in
  96 (x[[6789]])
  97         cf_dft_chtype=uint32_t
  98         cf_dft_ext_colors=yes
  99         cf_dft_ext_const=yes
 100         cf_dft_ext_mouse=yes
 101         cf_dft_ext_putwin=yes
 102         cf_dft_ext_spfuncs=yes
 103         cf_dft_filter_syms=yes
 104         cf_dft_interop=yes
 105         cf_dft_mmask_t=uint32_t
 106         cf_dft_opaque_curses=yes
 107         cf_dft_tparm_arg=intptr_t
 108         cf_dft_widec=yes
 109         cf_dft_with_lp64=yes
 110         ;;
 111 esac
 112
 113 # ABI 7 default differences from ABI 6:
 114 case x$cf_cv_abi_default in
 115 (x[[789]])
 116         cf_dft_ccharw_max=6
 117         cf_dft_mmask_t=uint64_t
 118         cf_dft_ordinate_type=int
 119         cf_dft_signed_char=yes
 120         # also: remove the wgetch-events feature in ABI 7
 121         ;;
 122 esac
 123 ])dnl
 124 dnl ---------------------------------------------------------------------------
 125 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 126 dnl ------------------
 127 dnl Conditionally generate script according to whether we're using a given autoconf.
 128 dnl
 129 dnl $1 = version to compare against
 130 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 131 dnl $3 = code to use if AC_ACVERSION is older than $1.
 132 define([CF_ACVERSION_CHECK],
 133 [
 134 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 135 ifdef([m4_version_compare],
 136 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 137 [CF_ACVERSION_COMPARE(
 138 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 139 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 140 dnl ---------------------------------------------------------------------------
 141 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 142 dnl --------------------
 143 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 144 dnl                      MAJOR2, MINOR2, TERNARY2,
 145 dnl                      PRINTABLE2, not FOUND, FOUND)
 146 define([CF_ACVERSION_COMPARE],
 147 [ifelse(builtin([eval], [$2 < $5]), 1,
 148 [ifelse([$8], , ,[$8])],
 149 [ifelse([$9], , ,[$9])])])dnl
 150 dnl ---------------------------------------------------------------------------
 151 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 152 dnl -------------------
 153 dnl Construct the list of include-options for the C programs in the Ada95
 154 dnl binding.
 155 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 156 [
 157 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 158 if test "$srcdir" != "."; then
 159         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 160 fi
 161 if test "$GCC" != yes; then
 162         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 163 elif test "$includedir" != "/usr/include"; then
 164         if test "$includedir" = '${prefix}/include' ; then
 165                 if test x$prefix != x/usr ; then
 166                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 167                 fi
 168         else
 169                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 170         fi
 171 fi
 172 AC_SUBST(ACPPFLAGS)
 173 ])dnl
 174 dnl ---------------------------------------------------------------------------
 175 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 176 dnl ---------------
 177 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 178 AC_DEFUN([CF_ADD_ADAFLAGS],[
 179         ADAFLAGS="$ADAFLAGS $1"
 180         AC_SUBST(ADAFLAGS)
 181 ])dnl
 182 dnl ---------------------------------------------------------------------------
 183 dnl CF_ADD_CFLAGS version: 15 updated: 2020/12/31 10:54:15
 184 dnl -------------
 185 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 186 dnl $1 = flags to add
 187 dnl $2 = if given makes this macro verbose.
 188 dnl
 189 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 190 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 191 dnl confused by the quotes (which require backslashes to keep them usable).
 192 AC_DEFUN([CF_ADD_CFLAGS],
 193 [
 194 cf_fix_cppflags=no
 195 cf_new_cflags=
 196 cf_new_cppflags=
 197 cf_new_extra_cppflags=
 198
 199 for cf_add_cflags in $1
 200 do
 201 case "$cf_fix_cppflags" in
 202 (no)
 203         case "$cf_add_cflags" in
 204         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 205                 case "$cf_add_cflags" in
 206                 (-D*)
 207                         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 208
 209                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 210                                 && test -z "${cf_tst_cflags}" \
 211                                 && cf_fix_cppflags=yes
 212
 213                         if test "$cf_fix_cppflags" = yes ; then
 214                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 215                                 continue
 216                         elif test "${cf_tst_cflags}" = "\"'" ; then
 217                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 218                                 continue
 219                         fi
 220                         ;;
 221                 esac
 222                 case "$CPPFLAGS" in
 223                 (*$cf_add_cflags)
 224                         ;;
 225                 (*)
 226                         case "$cf_add_cflags" in
 227                         (-D*)
 228                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 229                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 230                                 ;;
 231                         esac
 232                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 233                         ;;
 234                 esac
 235                 ;;
 236         (*)
 237                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 238                 ;;
 239         esac
 240         ;;
 241 (yes)
 242         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 243
 244         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^[[^"]]*"'\''//'`
 245
 246         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 247                 && test -z "${cf_tst_cflags}" \
 248                 && cf_fix_cppflags=no
 249         ;;
 250 esac
 251 done
 252
 253 if test -n "$cf_new_cflags" ; then
 254         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 255         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 256 fi
 257
 258 if test -n "$cf_new_cppflags" ; then
 259         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 260         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 261 fi
 262
 263 if test -n "$cf_new_extra_cppflags" ; then
 264         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 265         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 266 fi
 267
 268 AC_SUBST(EXTRA_CPPFLAGS)
 269
 270 ])dnl
 271 dnl ---------------------------------------------------------------------------
 272 dnl CF_ADD_CXXFLAGS version: 1 updated: 2020/04/04 16:16:13
 273 dnl ---------------
 274 dnl Copy non-preprocessor flags to $CXXFLAGS, preprocessor flags to $CPPFLAGS
 275 dnl The second parameter if given makes this macro verbose.
 276 dnl
 277 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 278 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 279 dnl confused by the quotes (which require backslashes to keep them usable).
 280 AC_DEFUN([CF_ADD_CXXFLAGS],
 281 [
 282 cf_save_CXXFLAGS="$CFLAGS"
 283 CFLAGS="$CXXFLAGS"
 284 CF_ADD_CFLAGS($1 ifelse($2,,,[,$2]))
 285 CXXFLAGS="$CFLAGS"
 286 CFLAGS="$cf_save_CXXFLAGS"
 287 ])dnl
 288 dnl ---------------------------------------------------------------------------
 289 dnl CF_ADD_INCDIR version: 17 updated: 2021/09/04 06:35:04
 290 dnl -------------
 291 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it is
 292 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 293 dnl but old versions (and some misinstalled ones) need that.  To make things
 294 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 295 dnl the include-path).
 296 AC_DEFUN([CF_ADD_INCDIR],
 297 [
 298 if test -n "$1" ; then
 299   for cf_add_incdir in $1
 300   do
 301         while test "$cf_add_incdir" != /usr/include
 302         do
 303           if test -d "$cf_add_incdir"
 304           then
 305                 cf_have_incdir=no
 306                 if test -n "$CFLAGS$CPPFLAGS" ; then
 307                   # a loop is needed to ensure we can add subdirs of existing dirs
 308                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 309                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 310                           cf_have_incdir=yes; break
 311                         fi
 312                   done
 313                 fi
 314
 315                 if test "$cf_have_incdir" = no ; then
 316                   if test "$cf_add_incdir" = /usr/local/include ; then
 317                         if test "$GCC" = yes
 318                         then
 319                           cf_save_CPPFLAGS=$CPPFLAGS
 320                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 321                           AC_TRY_COMPILE([#include <stdio.h>],
 322                                   [printf("Hello")],
 323                                   [],
 324                                   [cf_have_incdir=yes])
 325                           CPPFLAGS=$cf_save_CPPFLAGS
 326                         fi
 327                   fi
 328                 fi
 329
 330                 if test "$cf_have_incdir" = no ; then
 331                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 332                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 333
 334                   cf_top_incdir=`echo "$cf_add_incdir" | sed -e 's%/include/.*$%/include%'`
 335                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 336                   cf_add_incdir="$cf_top_incdir"
 337                 else
 338                   break
 339                 fi
 340           else
 341                 break
 342           fi
 343         done
 344   done
 345 fi
 346 ])dnl
 347 dnl ---------------------------------------------------------------------------
 348 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 349 dnl ----------
 350 dnl Add a library, used to enforce consistency.
 351 dnl
 352 dnl $1 = library to add, without the "-l"
 353 dnl $2 = variable to update (default $LIBS)
 354 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 355 dnl ---------------------------------------------------------------------------
 356 dnl CF_ADD_LIBDIR version: 11 updated: 2020/12/31 20:19:42
 357 dnl -------------
 358 dnl     Adds to the library-path
 359 dnl
 360 dnl     Some machines have trouble with multiple -L options.
 361 dnl
 362 dnl $1 is the (list of) directory(s) to add
 363 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 364 dnl
 365 AC_DEFUN([CF_ADD_LIBDIR],
 366 [
 367 if test -n "$1" ; then
 368         for cf_add_libdir in $1
 369         do
 370                 if test "$cf_add_libdir" = /usr/lib ; then
 371                         :
 372                 elif test -d "$cf_add_libdir"
 373                 then
 374                         cf_have_libdir=no
 375                         if test -n "$LDFLAGS$LIBS" ; then
 376                                 # a loop is needed to ensure we can add subdirs of existing dirs
 377                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 378                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 379                                                 cf_have_libdir=yes; break
 380                                         fi
 381                                 done
 382                         fi
 383                         if test "$cf_have_libdir" = no ; then
 384                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 385                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 386                         fi
 387                 fi
 388         done
 389 fi
 390 ])dnl
 391 dnl ---------------------------------------------------------------------------
 392 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
 393 dnl -----------
 394 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 395 dnl prepended to an existing list, since their dependencies are assumed to
 396 dnl already exist in the list.
 397 dnl
 398 dnl $1 = libraries to add, with the "-l", etc.
 399 dnl $2 = variable to update (default $LIBS)
 400 AC_DEFUN([CF_ADD_LIBS],[
 401 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
 402 # reverse order
 403 cf_add_0lib=
 404 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
 405 # filter duplicates
 406 for cf_add_1lib in $cf_add_0lib; do
 407         for cf_add_2lib in $cf_add_libs; do
 408                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
 409                         cf_add_1lib=
 410                         break
 411                 fi
 412         done
 413         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
 414 done
 415 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 416 ])dnl
 417 dnl ---------------------------------------------------------------------------
 418 dnl CF_ADD_SUBDIR_PATH version: 5 updated: 2020/12/31 20:19:42
 419 dnl ------------------
 420 dnl Append to a search-list for a nonstandard header/lib-file
 421 dnl     $1 = the variable to return as result
 422 dnl     $2 = the package name
 423 dnl     $3 = the subdirectory, e.g., bin, include or lib
 424 dnl $4 = the directory under which we will test for subdirectories
 425 dnl $5 = a directory that we do not want $4 to match
 426 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 427 [
 428 test "x$4" != "x$5" && \
 429 test -d "$4" && \
 430 ifelse([$5],NONE,,[{ test -z "$5" || test "x$5" = xNONE || test "x$4" != "x$5"; } &&]) {
 431         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 432         test -d "$4/$3" &&          $1="[$]$1 $4/$3"
 433         test -d "$4/$3/$2" &&       $1="[$]$1 $4/$3/$2"
 434         test -d "$4/$3/$2/$3" &&    $1="[$]$1 $4/$3/$2/$3"
 435         test -d "$4/$2/$3" &&       $1="[$]$1 $4/$2/$3"
 436         test -d "$4/$2/$3/$2" &&    $1="[$]$1 $4/$2/$3/$2"
 437 }
 438 ])dnl
 439 dnl ---------------------------------------------------------------------------
 440 dnl CF_APPEND_CFLAGS version: 3 updated: 2021/09/05 17:25:40
 441 dnl ----------------
 442 dnl Use CF_ADD_CFLAGS after first checking for potential redefinitions.
 443 dnl $1 = flags to add
 444 dnl $2 = if given makes this macro verbose.
 445 define([CF_APPEND_CFLAGS],
 446 [
 447 for cf_add_cflags in $1
 448 do
 449         case "x$cf_add_cflags" in
 450         (x-[[DU]]*)
 451                 CF_REMOVE_CFLAGS($cf_add_cflags,CFLAGS,[$2])
 452                 CF_REMOVE_CFLAGS($cf_add_cflags,CPPFLAGS,[$2])
 453                 ;;
 454         esac
 455         CF_ADD_CFLAGS([$cf_add_cflags],[$2])
 456 done
 457 ])dnl
 458 dnl ---------------------------------------------------------------------------
 459 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 460 dnl --------------
 461 dnl use this macro for appending text without introducing an extra blank at
 462 dnl the beginning
 463 define([CF_APPEND_TEXT],
 464 [
 465         test -n "[$]$1" && $1="[$]$1 "
 466         $1="[$]{$1}$2"
 467 ])dnl
 468 dnl ---------------------------------------------------------------------------
 469 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 470 dnl --------------
 471 dnl Allow user to disable a normally-on option.
 472 AC_DEFUN([CF_ARG_DISABLE],
 473 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 474 dnl ---------------------------------------------------------------------------
 475 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 476 dnl -------------
 477 dnl Allow user to enable a normally-off option.
 478 AC_DEFUN([CF_ARG_ENABLE],
 479 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 480 dnl ---------------------------------------------------------------------------
 481 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 482 dnl -------------
 483 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 484 dnl values.
 485 dnl
 486 dnl Parameters:
 487 dnl $1 = option name
 488 dnl $2 = help-string
 489 dnl $3 = action to perform if option is not default
 490 dnl $4 = action if perform if option is default
 491 dnl $5 = default option value (either 'yes' or 'no')
 492 AC_DEFUN([CF_ARG_OPTION],
 493 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 494         if test "$enableval" != "$5" ; then
 495 ifelse([$3],,[    :]dnl
 496 ,[    $3]) ifelse([$4],,,[
 497         else
 498                 $4])
 499         fi],[enableval=$5 ifelse([$4],,,[
 500         $4
 501 ])dnl
 502 ])])dnl
 503 dnl ---------------------------------------------------------------------------
 504 dnl CF_AR_FLAGS version: 9 updated: 2021/01/01 13:31:04
 505 dnl -----------
 506 dnl Check for suitable "ar" (archiver) options for updating an archive.
 507 dnl
 508 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 509 dnl as well as a workaround for breakage of make's archive rules by the GNU
 510 dnl binutils "ar" program.
 511 AC_DEFUN([CF_AR_FLAGS],[
 512 AC_REQUIRE([CF_PROG_AR])
 513
 514 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 515         case "$cf_cv_system_name" in
 516         (*-msvc*)
 517                 cf_cv_ar_flags=''
 518                 cat >mk_static_lib.sh <<-EOF
 519                 #!$SHELL
 520                 MSVC_BIN="[$]AR"
 521                 out="\[$]1"
 522                 shift
 523                 exec \[$]MSVC_BIN -out:"\[$]out" \[$]@
 524                 EOF
 525                 chmod +x mk_static_lib.sh
 526                 AR=`pwd`/mk_static_lib.sh
 527                 ;;
 528         (*)
 529                 cf_cv_ar_flags=unknown
 530                 for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 531                 do
 532
 533                         # check if $ARFLAGS already contains this choice
 534                         if test "x$ARFLAGS" != "x" ; then
 535                                 cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 536                                 if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 537                                         cf_cv_ar_flags=
 538                                         break
 539                                 fi
 540                         fi
 541
 542                         rm -f "conftest.$ac_cv_objext"
 543                         rm -f conftest.a
 544
 545                         cat >"conftest.$ac_ext" <<EOF
 546 #line __oline__ "configure"
 547 int     testdata[[3]] = { 123, 456, 789 };
 548 EOF
 549                         if AC_TRY_EVAL(ac_compile) ; then
 550                                 echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 551                                 $AR $ARFLAGS "$cf_ar_flags" conftest.a "conftest.$ac_cv_objext" 2>&AC_FD_CC 1>/dev/null
 552                                 if test -f conftest.a ; then
 553                                         cf_cv_ar_flags="$cf_ar_flags"
 554                                         break
 555                                 fi
 556                         else
 557                                 CF_VERBOSE(cannot compile test-program)
 558                                 break
 559                         fi
 560                 done
 561                 rm -f conftest.a "conftest.$ac_ext" "conftest.$ac_cv_objext"
 562                 ;;
 563         esac
 564 ])
 565
 566 if test -n "$ARFLAGS" ; then
 567         if test -n "$cf_cv_ar_flags" ; then
 568                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 569         fi
 570 else
 571         ARFLAGS=$cf_cv_ar_flags
 572 fi
 573
 574 AC_SUBST(ARFLAGS)
 575 ])
 576 dnl ---------------------------------------------------------------------------
 577 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 578 dnl -----------------
 579 dnl Check if awk can handle big strings using printf.  Some older versions of
 580 dnl awk choke on large strings passed via "%s".
 581 dnl
 582 dnl $1 = desired string size
 583 dnl $2 = variable to set with result
 584 AC_DEFUN([CF_AWK_BIG_PRINTF],
 585 [
 586         case x$AWK in
 587         (x)
 588                 eval $2=no
 589                 ;;
 590         (*)
 591                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 592                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 593                         eval $2=yes
 594                 else
 595                         eval $2=no
 596                 fi
 597                 ;;
 598         esac
 599 ])dnl
 600 dnl ---------------------------------------------------------------------------
 601 dnl CF_BOOL_DECL version: 9 updated: 2023/12/03 09:21:34
 602 dnl ------------
 603 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 604 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 605 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 606 dnl
 607 dnl Treat the configuration-variable specially here, since we're directly
 608 dnl substituting its value (i.e., 1/0).
 609 dnl
 610 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 611 AC_DEFUN([CF_BOOL_DECL],
 612 [
 613 AC_MSG_CHECKING(if we should include stdbool.h)
 614
 615 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 616         AC_TRY_COMPILE([],[bool foo = false; (void)foo],
 617                 [cf_cv_header_stdbool_h=0],
 618                 [AC_TRY_COMPILE([
 619 #ifndef __BEOS__
 620 #include <stdbool.h>
 621 #endif
 622 ],[bool foo = false; (void)foo],
 623                         [cf_cv_header_stdbool_h=1],
 624                         [cf_cv_header_stdbool_h=0])])])
 625
 626 if test "$cf_cv_header_stdbool_h" = 1
 627 then    AC_MSG_RESULT(yes)
 628 else    AC_MSG_RESULT(no)
 629 fi
 630
 631 AC_MSG_CHECKING([for builtin bool type])
 632
 633 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 634         AC_TRY_COMPILE([
 635 #include <stdio.h>
 636 #include <sys/types.h>
 637 ],[bool x = false; (void)x],
 638                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 639                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 640         ])
 641
 642 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 643 then    AC_MSG_RESULT(yes)
 644 else    AC_MSG_RESULT(no)
 645 fi
 646 ])dnl
 647 dnl ---------------------------------------------------------------------------
 648 dnl CF_BOOL_SIZE version: 20 updated: 2023/02/18 17:41:25
 649 dnl ------------
 650 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 651 dnl Don't bother looking for bool.h, since it has been deprecated.
 652 dnl
 653 dnl If the current compiler is C rather than C++, we get the bool definition
 654 dnl from <stdbool.h>.
 655 AC_DEFUN([CF_BOOL_SIZE],
 656 [
 657 AC_CHECK_SIZEOF(bool,,[
 658 $ac_includes_default
 659
 660 #if defined(__cplusplus)
 661
 662 #ifdef HAVE_GXX_BUILTIN_H
 663 #include <g++/builtin.h>
 664 #elif HAVE_GPP_BUILTIN_H
 665 #include <gpp/builtin.h>
 666 #elif HAVE_BUILTIN_H
 667 #include <builtin.h>
 668 #endif
 669
 670 #else
 671
 672 #if $cf_cv_header_stdbool_h
 673 #include <stdbool.h>
 674 #endif
 675
 676 #endif
 677 ])
 678
 679 AC_CACHE_CHECK(for type of bool, cf_cv_type_of_bool,[
 680         rm -f cf_test.out
 681         AC_TRY_RUN([
 682 $ac_includes_default
 683
 684 #if defined(__cplusplus)
 685
 686 #ifdef HAVE_GXX_BUILTIN_H
 687 #include <g++/builtin.h>
 688 #elif HAVE_GPP_BUILTIN_H
 689 #include <gpp/builtin.h>
 690 #elif HAVE_BUILTIN_H
 691 #include <builtin.h>
 692 #endif
 693
 694 #else
 695
 696 #if $cf_cv_header_stdbool_h
 697 #include <stdbool.h>
 698 #endif
 699
 700 #endif
 701
 702 int main(void)
 703 {
 704         FILE *fp = fopen("cf_test.out", "w");
 705         if (fp != 0) {
 706                 bool x = true;
 707                 if ((bool)(-x) >= 0)
 708                         fputs("unsigned ", fp);
 709                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 710                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 711                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 712                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 713                 fclose(fp);
 714         }
 715         ${cf_cv_main_return:-return}(0);
 716 }
 717                 ],
 718                 [cf_cv_type_of_bool=`cat cf_test.out`
 719                  if test -z "$cf_cv_type_of_bool"; then
 720                    cf_cv_type_of_bool=unknown
 721                  fi],
 722                 [cf_cv_type_of_bool=unknown],
 723                 [
 724                 case x$ac_cv_sizeof_bool in
 725                 (x1) cf_cv_type_of_bool="unsigned char";;
 726                 (x2) cf_cv_type_of_bool="unsigned short";;
 727                 (x4) cf_cv_type_of_bool="unsigned int";;
 728                 (x8) cf_cv_type_of_bool="unsigned long";;
 729                 (*)  cf_cv_type_of_bool=unknown;;
 730                 esac
 731                 ])
 732         rm -f cf_test.out
 733 ])
 734
 735 if test "$cf_cv_type_of_bool" = unknown ; then
 736         case .$NCURSES_BOOL in
 737         (.auto|.) NCURSES_BOOL=unsigned;;
 738         esac
 739         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 740         cf_cv_type_of_bool=$NCURSES_BOOL
 741 fi
 742 ])dnl
 743 dnl ---------------------------------------------------------------------------
 744 dnl CF_BUILD_CC version: 11 updated: 2022/12/04 15:40:08
 745 dnl -----------
 746 dnl If we're cross-compiling, allow the user to override the tools and their
 747 dnl options.  The configure script is oriented toward identifying the host
 748 dnl compiler, etc., but we need a build compiler to generate parts of the
 749 dnl source.
 750 dnl
 751 dnl $1 = default for $CPPFLAGS
 752 dnl $2 = default for $LIBS
 753 AC_DEFUN([CF_BUILD_CC],[
 754 CF_ACVERSION_CHECK(2.52,,
 755         [AC_REQUIRE([CF_PROG_EXT])])
 756 if test "$cross_compiling" = yes ; then
 757
 758         # defaults that we might want to override
 759         : ${BUILD_CFLAGS:=''}
 760         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 761         : ${BUILD_LDFLAGS:=''}
 762         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 763         : ${BUILD_EXEEXT:='$x'}
 764         : ${BUILD_OBJEXT:='o'}
 765
 766         AC_ARG_WITH(build-cc,
 767                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 768                 [BUILD_CC="$withval"],
 769                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 770         AC_MSG_CHECKING(for native build C compiler)
 771         AC_MSG_RESULT($BUILD_CC)
 772
 773         AC_MSG_CHECKING(for native build C preprocessor)
 774         AC_ARG_WITH(build-cpp,
 775                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 776                 [BUILD_CPP="$withval"],
 777                 [BUILD_CPP='${BUILD_CC} -E'])
 778         AC_MSG_RESULT($BUILD_CPP)
 779
 780         AC_MSG_CHECKING(for native build C flags)
 781         AC_ARG_WITH(build-cflags,
 782                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 783                 [BUILD_CFLAGS="$withval"])
 784         AC_MSG_RESULT($BUILD_CFLAGS)
 785
 786         AC_MSG_CHECKING(for native build C preprocessor-flags)
 787         AC_ARG_WITH(build-cppflags,
 788                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 789                 [BUILD_CPPFLAGS="$withval"])
 790         AC_MSG_RESULT($BUILD_CPPFLAGS)
 791
 792         AC_MSG_CHECKING(for native build linker-flags)
 793         AC_ARG_WITH(build-ldflags,
 794                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 795                 [BUILD_LDFLAGS="$withval"])
 796         AC_MSG_RESULT($BUILD_LDFLAGS)
 797
 798         AC_MSG_CHECKING(for native build linker-libraries)
 799         AC_ARG_WITH(build-libs,
 800                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 801                 [BUILD_LIBS="$withval"])
 802         AC_MSG_RESULT($BUILD_LIBS)
 803
 804         # this assumes we're on Unix.
 805         BUILD_EXEEXT=
 806         BUILD_OBJEXT=o
 807
 808         : ${BUILD_CC:='${CC}'}
 809
 810         AC_MSG_CHECKING(if the build-compiler "$BUILD_CC" works)
 811
 812         cf_save_crossed=$cross_compiling
 813         cf_save_ac_link=$ac_link
 814         cross_compiling=no
 815         cf_build_cppflags=$BUILD_CPPFLAGS
 816         test "$cf_build_cppflags" = "#" && cf_build_cppflags=
 817         ac_link='$BUILD_CC -o "conftest$ac_exeext" $BUILD_CFLAGS $cf_build_cppflags $BUILD_LDFLAGS "conftest.$ac_ext" $BUILD_LIBS >&AS_MESSAGE_LOG_FD'
 818
 819         AC_TRY_RUN([#include <stdio.h>
 820                 int main(int argc, char *argv[])
 821                 {
 822                         ${cf_cv_main_return:-return}(argc < 0 || argv == 0 || argv[0] == 0);
 823                 }
 824         ],
 825                 cf_ok_build_cc=yes,
 826                 cf_ok_build_cc=no,
 827                 cf_ok_build_cc=unknown)
 828
 829         cross_compiling=$cf_save_crossed
 830         ac_link=$cf_save_ac_link
 831
 832         AC_MSG_RESULT($cf_ok_build_cc)
 833
 834         if test "$cf_ok_build_cc" != yes
 835         then
 836                 AC_MSG_ERROR([Cross-build requires two compilers.
 837 Use --with-build-cc to specify the native compiler.])
 838         fi
 839
 840 else
 841         : ${BUILD_CC:='${CC}'}
 842         : ${BUILD_CPP:='${CPP}'}
 843         : ${BUILD_CFLAGS:='${CFLAGS}'}
 844         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 845         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 846         : ${BUILD_LIBS:='${LIBS}'}
 847         : ${BUILD_EXEEXT:='$x'}
 848         : ${BUILD_OBJEXT:='o'}
 849 fi
 850
 851 AC_SUBST(BUILD_CC)
 852 AC_SUBST(BUILD_CPP)
 853 AC_SUBST(BUILD_CFLAGS)
 854 AC_SUBST(BUILD_CPPFLAGS)
 855 AC_SUBST(BUILD_LDFLAGS)
 856 AC_SUBST(BUILD_LIBS)
 857 AC_SUBST(BUILD_EXEEXT)
 858 AC_SUBST(BUILD_OBJEXT)
 859 ])dnl
 860 dnl ---------------------------------------------------------------------------
 861 dnl CF_C11_NORETURN version: 4 updated: 2023/02/18 17:41:25
 862 dnl ---------------
 863 AC_DEFUN([CF_C11_NORETURN],
 864 [
 865 AC_MSG_CHECKING(if you want to use C11 _Noreturn feature)
 866 CF_ARG_ENABLE(stdnoreturn,
 867         [  --enable-stdnoreturn    enable C11 _Noreturn feature for diagnostics],
 868         [enable_stdnoreturn=yes],
 869         [enable_stdnoreturn=no])
 870 AC_MSG_RESULT($enable_stdnoreturn)
 871
 872 if test $enable_stdnoreturn = yes; then
 873 AC_CACHE_CHECK([for C11 _Noreturn feature], cf_cv_c11_noreturn,
 874         [AC_TRY_COMPILE([
 875 $ac_includes_default
 876 #include <stdnoreturn.h>
 877 static _Noreturn void giveup(void) { exit(0); }
 878         ],
 879         [if (feof(stdin)) giveup()],
 880         cf_cv_c11_noreturn=yes,
 881         cf_cv_c11_noreturn=no)
 882         ])
 883 else
 884         cf_cv_c11_noreturn=no,
 885 fi
 886
 887 if test "$cf_cv_c11_noreturn" = yes; then
 888         AC_DEFINE(HAVE_STDNORETURN_H, 1,[Define if <stdnoreturn.h> header is available and working])
 889         AC_DEFINE_UNQUOTED(STDC_NORETURN,_Noreturn,[Define if C11 _Noreturn keyword is supported])
 890         HAVE_STDNORETURN_H=1
 891 else
 892         HAVE_STDNORETURN_H=0
 893 fi
 894
 895 AC_SUBST(HAVE_STDNORETURN_H)
 896 AC_SUBST(STDC_NORETURN)
 897 ])dnl
 898 dnl ---------------------------------------------------------------------------
 899 dnl CF_CC_ENV_FLAGS version: 11 updated: 2023/02/20 11:15:46
 900 dnl ---------------
 901 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 902 dnl into CC.  This will not help with broken scripts that wrap the compiler
 903 dnl with options, but eliminates a more common category of user confusion.
 904 dnl
 905 dnl In particular, it addresses the problem of being able to run the C
 906 dnl preprocessor in a consistent manner.
 907 dnl
 908 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 909 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 910 dnl outweighs that limitation.
 911 AC_DEFUN([CF_CC_ENV_FLAGS],
 912 [
 913 # This should have been defined by AC_PROG_CC
 914 : "${CC:=cc}"
 915
 916 AC_MSG_CHECKING(\$CFLAGS variable)
 917 case "x$CFLAGS" in
 918 (*-[[IUD]]*)
 919         AC_MSG_RESULT(broken)
 920         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 921         cf_flags="$CFLAGS"
 922         CFLAGS=
 923         for cf_arg in $cf_flags
 924         do
 925                 CF_ADD_CFLAGS($cf_arg)
 926         done
 927         ;;
 928 (*)
 929         AC_MSG_RESULT(ok)
 930         ;;
 931 esac
 932
 933 AC_MSG_CHECKING(\$CC variable)
 934 case "$CC" in
 935 (*[[\ \ ]]-*)
 936         AC_MSG_RESULT(broken)
 937         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 938         # humor him...
 939         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 940         cf_flags=`echo "$CC" | sed -e "s%^$cf_prog%%"`
 941         CC="$cf_prog"
 942         for cf_arg in $cf_flags
 943         do
 944                 case "x$cf_arg" in
 945                 (x-[[IUDfgOW]]*)
 946                         CF_ADD_CFLAGS($cf_arg)
 947                         ;;
 948                 (*)
 949                         CC="$CC $cf_arg"
 950                         ;;
 951                 esac
 952         done
 953         CF_VERBOSE(resulting CC: '$CC')
 954         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 955         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 956         ;;
 957 (*)
 958         AC_MSG_RESULT(ok)
 959         ;;
 960 esac
 961 ])dnl
 962 dnl ---------------------------------------------------------------------------
 963 dnl CF_CFG_DEFAULTS version: 16 updated: 2021/01/04 19:33:05
 964 dnl ---------------
 965 dnl Determine the default configuration into which we'll install ncurses.  This
 966 dnl can be overridden by the user's command-line options.  There's two items to
 967 dnl look for:
 968 dnl     1. the prefix (e.g., /usr)
 969 dnl     2. the header files (e.g., /usr/include/ncurses)
 970 dnl We'll look for a previous installation of ncurses and use the same defaults.
 971 dnl
 972 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 973 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 974 dnl programs from a vendor's.
 975 AC_DEFUN([CF_CFG_DEFAULTS],
 976 [AC_REQUIRE([AC_PROG_FGREP])dnl
 977
 978 AC_MSG_CHECKING(for prefix)
 979 if test "x$prefix" = "xNONE" ; then
 980         case "$cf_cv_system_name" in
 981                 # non-vendor systems don't have a conflict
 982         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 983                 prefix=/usr
 984                 ;;
 985         (*)     prefix=$ac_default_prefix
 986                 ;;
 987         esac
 988 fi
 989 AC_MSG_RESULT($prefix)
 990
 991 if test "x$prefix" = "xNONE" ; then
 992 AC_MSG_CHECKING(for default include-directory)
 993 test -n "$verbose" && echo 1>&AC_FD_MSG
 994 for cf_symbol in \
 995         "$includedir" \
 996         "$includedir/ncurses" \
 997         "$prefix/include" \
 998         "$prefix/include/ncurses" \
 999         /usr/local/include \
1000         /usr/local/include/ncurses \
1001         /usr/include \
1002         /usr/include/ncurses
1003 do
1004         cf_dir=`eval echo "$cf_symbol"`
1005         if test -f "$cf_dir/curses.h" ; then
1006         if ( ${FGREP-fgrep} NCURSES_VERSION "$cf_dir/curses.h" >/dev/null 2>&1 ) ; then
1007                 includedir="$cf_symbol"
1008                 test -n "$verbose"  && echo $ECHO_N "   found " 1>&AC_FD_MSG
1009                 break
1010         fi
1011         fi
1012         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
1013 done
1014 AC_MSG_RESULT($includedir)
1015 fi
1016 ])dnl
1017 dnl ---------------------------------------------------------------------------
1018 dnl CF_CGETENT version: 7 updated: 2023/02/18 17:41:25
1019 dnl ----------
1020 dnl Check if the terminal-capability database functions are available.  If not,
1021 dnl ncurses has a much-reduced version.
1022 AC_DEFUN([CF_CGETENT],[
1023 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
1024 AC_TRY_LINK([
1025 $ac_includes_default],[
1026         char temp[128];
1027         char *buf = temp;
1028         char *db_array = temp;
1029         cgetent(&buf, &db_array, "vt100");
1030         cgetcap(buf, "tc", '=');
1031         cgetmatch(buf, "tc");
1032         ],
1033         [cf_cv_cgetent=yes],
1034         [cf_cv_cgetent=no])
1035 ])
1036
1037 if test "$cf_cv_cgetent" = yes
1038 then
1039         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
1040 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
1041 AC_TRY_LINK([
1042 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
1043 $ac_includes_default],[
1044         char temp[128];
1045         char *buf = temp;
1046 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
1047         const char *db_array = temp;
1048         cgetent(&buf, &db_array, "vt100");
1049 #endif
1050         cgetcap(buf, "tc", '=');
1051         cgetmatch(buf, "tc");
1052         ],
1053         [cf_cv_cgetent_const=yes],
1054         [cf_cv_cgetent_const=no])
1055 ])
1056         if test "$cf_cv_cgetent_const" = yes
1057         then
1058                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
1059         fi
1060 fi
1061 ])dnl
1062 dnl ---------------------------------------------------------------------------
1063 dnl CF_CHECK_CACHE version: 13 updated: 2020/12/31 10:54:15
1064 dnl --------------
1065 dnl Check if we're accidentally using a cache from a different machine.
1066 dnl Derive the system name, as a check for reusing the autoconf cache.
1067 dnl
1068 dnl If we've packaged config.guess and config.sub, run that (since it does a
1069 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
1070 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
1071 dnl which is useful in cross-compiles.
1072 dnl
1073 dnl Note: we would use $ac_config_sub, but that is one of the places where
1074 dnl autoconf 2.5x broke compatibility with autoconf 2.13
1075 AC_DEFUN([CF_CHECK_CACHE],
1076 [
1077 if test -f "$srcdir/config.guess" || test -f "$ac_aux_dir/config.guess" ; then
1078         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
1079         system_name="$host_os"
1080 else
1081         system_name="`(uname -s -r) 2>/dev/null`"
1082         if test -z "$system_name" ; then
1083                 system_name="`(hostname) 2>/dev/null`"
1084         fi
1085 fi
1086 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
1087 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
1088
1089 test -z "$system_name" && system_name="$cf_cv_system_name"
1090 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
1091
1092 if test ".$system_name" != ".$cf_cv_system_name" ; then
1093         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
1094         AC_MSG_ERROR("Please remove config.cache and try again.")
1095 fi
1096 ])dnl
1097 dnl ---------------------------------------------------------------------------
1098 dnl CF_CHECK_ENVIRON version: 5 updated: 2023/02/18 17:41:25
1099 dnl ----------------
1100 dnl Check for data that is usually declared in <unistd.h>, e.g., the 'environ'
1101 dnl variable.  Define a DECL_xxx symbol if we must declare it ourselves.
1102 dnl
1103 dnl $1 = the name to check
1104 dnl $2 = the assumed type
1105 AC_DEFUN([CF_CHECK_ENVIRON],
1106 [
1107 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1108     AC_TRY_COMPILE([
1109 $ac_includes_default],
1110     ifelse([$2],,void*,[$2]) x = (ifelse([$2],,void*,[$2])) $1; (void)x,
1111     [cf_cv_dcl_$1=yes],
1112     [cf_cv_dcl_$1=no])
1113 ])
1114
1115 if test "$cf_cv_dcl_$1" = no ; then
1116     CF_UPPER(cf_result,decl_$1)
1117     AC_DEFINE_UNQUOTED($cf_result)
1118 fi
1119
1120 # It's possible (for near-UNIX clones) that the data doesn't exist
1121 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1122 ])dnl
1123 dnl ---------------------------------------------------------------------------
1124 dnl CF_CHECK_ERRNO version: 14 updated: 2023/02/18 17:41:25
1125 dnl --------------
1126 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
1127 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
1128 dnl ourselves.
1129 dnl
1130 dnl $1 = the name to check
1131 dnl $2 = the assumed type
1132 AC_DEFUN([CF_CHECK_ERRNO],
1133 [
1134 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1135         AC_TRY_COMPILE([
1136 $ac_includes_default
1137 #include <errno.h> ],
1138         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1; (void)x,
1139         [cf_cv_dcl_$1=yes],
1140         [cf_cv_dcl_$1=no])
1141 ])
1142
1143 if test "$cf_cv_dcl_$1" = no ; then
1144         CF_UPPER(cf_result,decl_$1)
1145         AC_DEFINE_UNQUOTED($cf_result)
1146 fi
1147
1148 # It's possible (for near-UNIX clones) that the data doesn't exist
1149 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1150 ])dnl
1151 dnl ---------------------------------------------------------------------------
1152 dnl CF_CHECK_EXTERN_DATA version: 5 updated: 2021/09/04 06:35:04
1153 dnl --------------------
1154 dnl Check for existence of external data in the current set of libraries.  If
1155 dnl we can modify it, it is real enough.
1156 dnl $1 = the name to check
1157 dnl $2 = its type
1158 AC_DEFUN([CF_CHECK_EXTERN_DATA],
1159 [
1160 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
1161         AC_TRY_LINK([
1162 #undef $1
1163 extern $2 $1;
1164 ],
1165         [$1 = 2],
1166         [cf_cv_have_$1=yes],
1167         [cf_cv_have_$1=no])
1168 ])
1169
1170 if test "$cf_cv_have_$1" = yes ; then
1171         CF_UPPER(cf_result,have_$1)
1172         AC_DEFINE_UNQUOTED($cf_result)
1173 fi
1174
1175 ])dnl
1176 dnl ---------------------------------------------------------------------------
1177 dnl CF_CHECK_FVISIBILITY version: 2 updated: 2020/04/04 16:16:13
1178 dnl --------------------
1179 dnl Check whether the compiler understands -fvisibility=hidden
1180 dnl
1181 dnl $1 = compiler
1182 dnl $2 = compiler-flags variable name
1183 dnl $3 = cache variable to set
1184 AC_DEFUN([CF_CHECK_FVISIBILITY],[
1185 AC_CACHE_CHECK(if $1 -fvisibility=hidden option works,$3,[
1186     cf_save_cflags="[$]$2"
1187     $2="[$]$2 -fvisibility=hidden"
1188     AC_TRY_LINK([
1189 __attribute__ ((visibility("default"))) int somefunc() {return 42;}
1190         ],[
1191         if (somefunc()) return 1;
1192 ],
1193     [$3=yes],
1194     [$3=no])
1195     $2=$cf_save_cflags
1196 ])
1197 ])dnl
1198 dnl ---------------------------------------------------------------------------
1199 dnl CF_CHECK_GETENV version: 4 updated: 2023/12/03 10:18:09
1200 dnl ---------------
1201 dnl Check if repeated getenv calls return the same pointer, e.g., it does not
1202 dnl discard the previous pointer when returning a new one.
1203 AC_DEFUN([CF_CHECK_GETENV],
1204 [
1205 AC_REQUIRE([CF_CHECK_ENVIRON])
1206 AC_CHECK_FUNC( getenv, ,, AC_MSG_ERROR(getenv not found) )
1207 AC_CHECK_FUNCS( putenv setenv strdup )
1208 AC_CACHE_CHECK(if getenv returns consistent values,cf_cv_consistent_getenv,[
1209 AC_TRY_RUN([
1210 $ac_includes_default
1211
1212 #if defined(HAVE_ENVIRON) && defined(DECL_ENVIRON) && !defined(environ)
1213 extern char **environ;  /* POSIX, but some systems are not... */
1214 #endif
1215
1216 #if defined(HAVE_STRDUP)
1217 #define str_alloc(s) strdup(s)
1218 #else
1219 #define str_alloc(s) strcpy(malloc(strlen(s) + 1, s))
1220 #endif
1221
1222 static void set_value(const char *name, const char *value)
1223 {
1224 #if defined(HAVE_SETENV)
1225         setenv(name, value, 1);
1226 #elif defined(HAVE_PUTENV)
1227         char buffer[1024];
1228         sprintf(buffer, "%s=%s", name, value);
1229         putenv(str_alloc(buffer));
1230 #else
1231 #error neither putenv/setenv found
1232 #endif
1233 }
1234 int main(void)
1235 {
1236         int pass;
1237         size_t numenv, limit, j;
1238         char **mynames;
1239         char **myvalues;
1240         char **mypointer;
1241         char *equals;
1242         for (numenv = 0; environ[numenv]; ++numenv) ;
1243         limit = numenv + 10;
1244         mynames = (char **) calloc(limit + 1, sizeof(char *));
1245         myvalues = (char **) calloc(limit + 1, sizeof(char *));
1246         mypointer = (char **) calloc(limit + 1, sizeof(char *));
1247 #if defined(HAVE_ENVIRON)
1248         for (j = 0; environ[j]; ++j) {
1249                 mynames[j] = str_alloc(environ[j]);
1250                 equals = strchr(mynames[j], '=');
1251                 if (equals != 0) {
1252                         *equals++ = '\\0';
1253                         myvalues[j] = str_alloc(equals);
1254                 } else {
1255                         myvalues[j] = str_alloc("");
1256                 }
1257         }
1258 #endif
1259         for (j = numenv; j < limit; ++j) {
1260                 char name[80];
1261                 char value[80];
1262                 size_t found;
1263                 size_t k = 0;
1264                 do {
1265                         size_t jk;
1266                         found = 0;
1267                         sprintf(name, "TERM%lu", (unsigned long) k);
1268                         for (jk = 0; jk < j; ++jk) {
1269                                 if (!strcmp(name, mynames[jk])) {
1270                                         found = 1;
1271                                         ++k;
1272                                         break;
1273                                 }
1274                         }
1275                 } while (found);
1276                 sprintf(value, "%lu:%p", (unsigned long) k, (void*)&mynames[j]);
1277                 set_value(name, value);
1278                 mynames[j] = str_alloc(name);
1279                 myvalues[j] = str_alloc(value);
1280         }
1281         for (pass = 0; pass < 3; ++pass) {
1282                 for (j = 0; j < limit; ++j) {
1283                         char *value = getenv(mynames[j]);
1284                         if (pass) {
1285                                 if (value == 0) {
1286                                         fprintf(stderr, "getenv returned null for %s\\n", mynames[j]);
1287                                         ${cf_cv_main_return:-return}(1);
1288                                 } else if (value != mypointer[j]) {
1289                                         fprintf(stderr, "getenv returned different pointer for %s\\n", mynames[j]);
1290                                         ${cf_cv_main_return:-return}(1);
1291                                 } else if (strcmp(value, myvalues[j])) {
1292                                         fprintf(stderr, "getenv returned different value for %s\\n", mynames[j]);
1293                                         ${cf_cv_main_return:-return}(1);
1294                                 }
1295                         } else {
1296                                 size_t k;
1297                                 mypointer[j] = value;
1298                                 for (k = 0; k < j; ++k) {
1299                                         if (mypointer[j] == mypointer[k]) {
1300                                                 fprintf(stderr, "getenv returned same pointer for %s and %s\\n", mynames[j], mynames[k]);
1301                                                 ${cf_cv_main_return:-return}(1);
1302                                         }
1303                                 }
1304                         }
1305                 }
1306         }
1307         ${cf_cv_main_return:-return}(0);
1308 }
1309 ],
1310 [cf_cv_consistent_getenv=yes],
1311 [cf_cv_consistent_getenv=no],
1312 [cf_cv_consistent_getenv=unknown])
1313 ])
1314
1315 if test "x$cf_cv_consistent_getenv" = xno
1316 then
1317         AC_DEFINE(HAVE_CONSISTENT_GETENV,1,[Define to 1 if getenv repeatably returns the same value for a given name])
1318 fi
1319 ])dnl
1320 dnl ---------------------------------------------------------------------------
1321 dnl CF_CHECK_GNAT_VERSION version: 4 updated: 2021/01/01 13:31:04
1322 dnl ---------------------
1323 AC_DEFUN([CF_CHECK_GNAT_VERSION],
1324 [
1325 AC_REQUIRE([CF_GNAT_VERSION])
1326 case "$cf_cv_gnat_version" in
1327 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
1328         cf_cv_prog_gnat_correct=yes
1329         ;;
1330 (*)
1331         AC_MSG_WARN(Unsupported GNAT version $cf_cv_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1332         cf_cv_prog_gnat_correct=no
1333         ;;
1334 esac
1335 ])
1336 dnl ---------------------------------------------------------------------------
1337 dnl CF_CHECK_GPM_WGETCH version: 6 updated: 2021/01/04 18:48:01
1338 dnl -------------------
1339 dnl Check if GPM is already linked with curses.  If so - and if the linkage
1340 dnl is not "weak" - warn about this because it can create problems linking
1341 dnl applications with ncurses.
1342 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
1343 AC_REQUIRE([AC_PROG_EGREP])dnl
1344
1345 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
1346
1347 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
1348 cf_cv_check_gpm_wgetch=unknown
1349 if test "$cross_compiling" != yes ; then
1350
1351 cat >conftest.$ac_ext <<CF_EOF
1352 #include <gpm.h>
1353 int main(void)
1354 {
1355         Gpm_Wgetch();
1356         ${cf_cv_main_return:-return}(0);
1357 }
1358 CF_EOF
1359
1360         cf_save_LIBS="$LIBS"
1361         # This only works if we can look at the symbol table.  If a shared
1362         # library is stripped for install, we cannot use that.  So we're forced
1363         # to rely on the static library, noting that some packagers may not
1364         # include it.
1365         LIBS="-static -lgpm -dynamic $LIBS"
1366         if AC_TRY_EVAL(ac_compile) ; then
1367                 if AC_TRY_EVAL(ac_link) ; then
1368                         cf_cv_check_gpm_wgetch="`nm \"conftest$ac_exeext\" | ${EGREP-egrep} '\<wgetch\>' | ${EGREP-egrep} '\<[[vVwW]]\>'`"
1369                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
1370                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
1371                 fi
1372         fi
1373         rm -rf ./conftest*
1374         LIBS="$cf_save_LIBS"
1375 fi
1376 ])
1377
1378 if test "$cf_cv_check_gpm_wgetch" != yes ; then
1379         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
1380 fi
1381 ])])dnl
1382 dnl ---------------------------------------------------------------------------
1383 dnl CF_CHECK_LIBSSP version: 1 updated: 2021/10/30 10:40:19
1384 dnl ---------------
1385 dnl Check if libssp is needed, e.g., to work around misconfigured libraries
1386 dnl used in cross-compiling to MinGW.
1387 AC_DEFUN([CF_CHECK_LIBSSP],[
1388 AC_CACHE_CHECK(if ssp library is needed,cf_cv_need_libssp,[
1389 AC_TRY_LINK([
1390 #include <sys/types.h>
1391 #include <dirent.h>
1392 ],[
1393        DIR *dp = opendir(".");
1394 ],cf_cv_need_libssp=no,[
1395         cf_save_LIBS="$LIBS"
1396         LIBS="$LIBS -lssp"
1397         AC_TRY_LINK([
1398 #include <sys/types.h>
1399 #include <dirent.h>
1400         ],[
1401                    DIR *dp = opendir(".");
1402         ],cf_cv_need_libssp=yes,
1403           cf_cv_need_libssp=maybe)
1404         LIBS="$cf_save_LIBS"
1405 ])dnl
1406 ])
1407
1408 if test "x$cf_cv_need_libssp" = xyes
1409 then
1410         CF_ADD_LIB(ssp)
1411 fi
1412 ])dnl
1413 dnl ---------------------------------------------------------------------------
1414 dnl CF_CHECK_LIBTOOL_VERSION version: 2 updated: 2021/05/01 16:24:34
1415 dnl ------------------------
1416 dnl Show the version of libtool
1417 dnl
1418 dnl Save the version in a cache variable - this is not entirely a good thing,
1419 dnl but the version string from libtool is very ugly, and for bug reports it
1420 dnl might be useful to have the original string.
1421 dnl
1422 dnl There is an imitation in OpenBSD, which has no apparent use other than to
1423 dnl deny that it is GNU libtool.  Just ignore it.
1424 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1425 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1426 then
1427         AC_MSG_CHECKING(version of $LIBTOOL)
1428         CF_LIBTOOL_VERSION
1429         AC_MSG_RESULT($cf_cv_libtool_version)
1430         if test -n "$cf_cv_libtool_version"
1431         then
1432                 cf_check_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' -e 's,[[()]],...,g' -e 's,[[ ]],-,g' -e '2,$d'`
1433                 case "x$cf_check_libtool_version" in
1434                 (*...GNU-libtool...*)
1435                         ;;
1436                 (*)
1437                         AC_MSG_ERROR(This is not GNU libtool)
1438                         ;;
1439                 esac
1440         else
1441                 AC_MSG_ERROR(No version found for $LIBTOOL)
1442         fi
1443 else
1444         AC_MSG_ERROR(GNU libtool has not been found)
1445 fi
1446 ])dnl
1447 dnl ---------------------------------------------------------------------------
1448 dnl CF_CHECK_WCHAR_H version: 5 updated: 2023/12/03 09:21:34
1449 dnl ----------------
1450 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1451 AC_DEFUN([CF_CHECK_WCHAR_H],[
1452 AC_CHECK_HEADERS( \
1453 wchar.h \
1454 wctype.h \
1455 )
1456 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1457 AC_TRY_COMPILE(
1458 [
1459 $ac_includes_default
1460 #ifdef HAVE_WCHAR_H
1461 #include <wchar.h>
1462 #endif
1463 #ifdef HAVE_WCTYPE_H
1464 #include <wctype.h>
1465 #endif
1466 ],[
1467         wint_t foo = 0;
1468         int bar = iswpunct(foo); (void) bar],
1469         [cf_cv_wchar_h_okay=yes],
1470         [cf_cv_wchar_h_okay=no])])
1471
1472 if test "$cf_cv_wchar_h_okay" = no
1473 then
1474         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1475 fi
1476 ])dnl
1477 dnl ---------------------------------------------------------------------------
1478 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 4 updated: 2023/12/03 10:17:07
1479 dnl -------------------------
1480 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1481 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1482 dnl
1483 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1484 dnl all of those were combined into a page of useful graphics characters.
1485 dnl
1486 dnl So far, so good.
1487 dnl
1488 dnl However, while they are useful, there are other considerations.  CJK
1489 dnl is (because of poor device resolution) often rendered as double-width
1490 dnl characters.  So... for these generally-useful characters, what should
1491 dnl be the width (to make them consistent with adjacent characters)?
1492 dnl
1493 dnl The obvious choice would have been to make this locale-dependent, and use
1494 dnl wcwidth() to tell applications what the actual width is.  That was too
1495 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1496 dnl See for example
1497 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1498 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1499 dnl
1500 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1501 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1502 dnl instance, it lists half (44/96) of the Latin-1 characters as
1503 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1504 dnl
1505 dnl What this means for the implementor is that on some systems wcwidth() can
1506 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1507 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1508 dnl characters).  These do not necessarily match the behavior of the terminal
1509 dnl emulator.  xterm, for instance, does an optional startup check to find if
1510 dnl this problem (or similar) exists with the system's locale tables, rejecting
1511 dnl them if they are too unreliable.
1512 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1513 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1514 cat >conftest.in <<CF_EOF
1515 -       VT100 symbols
1516 0x250c  upper left corner
1517 0x2514  lower left corner
1518 0x2510  upper right corner
1519 0x2518  lower right corner
1520 0x251c  tee pointing left
1521 0x2524  tee pointing right
1522 0x2534  tee pointing up
1523 0x252c  tee pointing down
1524 0x2500  horizontal line
1525 0x2502  vertical line
1526 0x253c  large plus or crossover
1527 0x23ba  scan line 1
1528 0x23bd  scan line 9
1529 0x25c6  diamond
1530 0x2592  checker board (stipple)
1531 0x00b0  degree symbol
1532 0x00b1  plus/minus
1533 0x00b7  bullet
1534 -       Teletype 5410v1 symbols
1535 0x2190  arrow pointing left
1536 0x2192  arrow pointing right
1537 0x2193  arrow pointing down
1538 0x2191  arrow pointing up
1539 0x2592  board of squares
1540 0x2603  lantern symbol
1541 0x25ae  solid square block
1542 -       these defaults were invented for ncurses
1543 0x23bb  scan line 3
1544 0x23bc  scan line 7
1545 0x2264  less-than-or-equal-to
1546 0x2265  greater-than-or-equal-to
1547 0x03c0  greek pi
1548 0x2260  not-equal
1549 0x00a3  pound-sterling symbol
1550 -       thick-line-drawing
1551 0x250f  upper left corner
1552 0x2517  lower left corner
1553 0x2513  upper right corner
1554 0x251b  lower right corner
1555 0x2523  tee pointing left
1556 0x252b  tee pointing right
1557 0x253b  tee pointing up
1558 0x2533  tee pointing down
1559 0x2501  horizontal line
1560 0x2503  vertical line
1561 0x254b  large plus or crossover
1562 -       double-line-drawing
1563 0x2554  upper left corner
1564 0x255a  lower left corner
1565 0x2557  upper right corner
1566 0x255d  lower right corner
1567 0x2563  tee pointing left
1568 0x2560  tee pointing right
1569 0x2569  tee pointing up
1570 0x2566  tee pointing down
1571 0x2550  horizontal line
1572 0x2551  vertical line
1573 0x256c  large plus or crossover
1574 CF_EOF
1575 AC_TRY_RUN([
1576 $ac_includes_default
1577
1578 #include <locale.h>
1579 #include <wchar.h>
1580
1581 #define MY_LEN 80
1582
1583 int
1584 main(void)
1585 {
1586         FILE *fp;
1587         unsigned value;
1588         char buffer[MY_LEN + 1];
1589         char notes[MY_LEN + 1];
1590         int totals = 0;
1591         int passed = 0;
1592
1593         if (setlocale(LC_ALL, "en_US.UTF8") ||
1594                 setlocale(LC_ALL, "en_US.UTF-8") ||
1595                 setlocale(LC_ALL, "en_US.utf8") ||
1596                 setlocale(LC_ALL, "en_US.utf-8")) {
1597                 if ((fp = fopen("conftest.in", "r")) != 0) {
1598                         while (fgets(buffer, MY_LEN, fp) != 0) {
1599                                 if (*buffer == '-') {
1600                                         fprintf(stderr, "\\t%s", buffer);
1601                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1602                                         ++totals;
1603                                         if (wcwidth((int)value) == 1)
1604                                                 ++passed;
1605                                         fprintf(stderr, "%d\\t%s", wcwidth((int)value), buffer);
1606                                 } else {
1607                                         fprintf(stderr, "?\\t%s", buffer);
1608                                 }
1609                         }
1610                 }
1611         }
1612         fprintf(stderr, "%d/%d passed wcwidth/graphics check\\n", passed, totals);
1613         return (totals == passed) ? 0 : 1;
1614 }
1615 ],
1616 [cf_cv_wcwidth_graphics=yes],
1617 [cf_cv_wcwidth_graphics=no],
1618 [cf_cv_wcwidth_graphics=unknown])
1619 ])
1620 ])dnl
1621 dnl ---------------------------------------------------------------------------
1622 dnl CF_CLANG_COMPILER version: 9 updated: 2023/02/18 17:41:25
1623 dnl -----------------
1624 dnl Check if the given compiler is really clang.  clang's C driver defines
1625 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1626 dnl not ignore some gcc options.
1627 dnl
1628 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1629 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1630 dnl the wrappers for gcc and g++ warnings.
1631 dnl
1632 dnl $1 = GCC (default) or GXX
1633 dnl $2 = CLANG_COMPILER (default)
1634 dnl $3 = CFLAGS (default) or CXXFLAGS
1635 AC_DEFUN([CF_CLANG_COMPILER],[
1636 ifelse([$2],,CLANG_COMPILER,[$2])=no
1637
1638 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1639         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1640         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1641         AC_TRY_COMPILE([],[
1642 #ifdef __clang__
1643 #else
1644 #error __clang__ is not defined
1645 #endif
1646 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1647 ],[])
1648         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1649         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1650 fi
1651
1652 CLANG_VERSION=none
1653
1654 if test "x$ifelse([$2],,CLANG_COMPILER,[$2])" = "xyes" ; then
1655         case "$CC" in
1656         (c[[1-9]][[0-9]]|*/c[[1-9]][[0-9]])
1657                 AC_MSG_WARN(replacing broken compiler alias $CC)
1658                 CFLAGS="$CFLAGS -std=`echo "$CC" | sed -e 's%.*/%%'`"
1659                 CC=clang
1660                 ;;
1661         esac
1662
1663         AC_MSG_CHECKING(version of $CC)
1664         CLANG_VERSION="`$CC --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(CLANG[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1665         test -z "$CLANG_VERSION" && CLANG_VERSION=unknown
1666         AC_MSG_RESULT($CLANG_VERSION)
1667
1668         for cf_clang_opt in \
1669                 -Qunused-arguments \
1670                 -Wno-error=implicit-function-declaration
1671         do
1672                 AC_MSG_CHECKING(if option $cf_clang_opt works)
1673                 cf_save_CFLAGS="$CFLAGS"
1674                 CFLAGS="$CFLAGS $cf_clang_opt"
1675                 AC_TRY_LINK([
1676                         #include <stdio.h>],[
1677                         printf("hello!\\n");],[
1678                         cf_clang_optok=yes],[
1679                         cf_clang_optok=no])
1680                 AC_MSG_RESULT($cf_clang_optok)
1681                 CFLAGS="$cf_save_CFLAGS"
1682                 if test "$cf_clang_optok" = yes; then
1683                         CF_VERBOSE(adding option $cf_clang_opt)
1684                         CF_APPEND_TEXT(CFLAGS,$cf_clang_opt)
1685                 fi
1686         done
1687 fi
1688 ])
1689 dnl ---------------------------------------------------------------------------
1690 dnl CF_CONST_X_STRING version: 8 updated: 2023/12/01 17:22:50
1691 dnl -----------------
1692 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
1693 dnl character-strings.
1694 dnl
1695 dnl It is ambiguous because the specification accommodated the pre-ANSI
1696 dnl compilers bundled by more than one vendor in lieu of providing a standard C
1697 dnl compiler other than by costly add-ons.  Because of this, the specification
1698 dnl did not take into account the use of const for telling the compiler that
1699 dnl string literals would be in readonly memory.
1700 dnl
1701 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
1702 dnl let the compiler decide how to represent Xt's strings which were #define'd.
1703 dnl That does not solve the problem of using the block of Xt's strings which
1704 dnl are compiled into the library (and is less efficient than one might want).
1705 dnl
1706 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
1707 dnl when compiling the library and compiling using the library, to tell the
1708 dnl compiler that String is const.
1709 AC_DEFUN([CF_CONST_X_STRING],
1710 [
1711 AC_REQUIRE([AC_PATH_XTRA])
1712
1713 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
1714
1715 AC_TRY_COMPILE(
1716 [
1717 #include <stdlib.h>
1718 #include <X11/Intrinsic.h>
1719 ],
1720 [String foo = malloc(1); free((void*)foo)],[
1721
1722 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
1723         AC_TRY_COMPILE(
1724                 [
1725 #undef  _CONST_X_STRING
1726 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
1727 #undef  XTSTRINGDEFINES /* X11R5 and later */
1728 #include <stdlib.h>
1729 #include <X11/Intrinsic.h>
1730                 ],[String foo = malloc(1); *foo = 0],[
1731                         cf_cv_const_x_string=no
1732                 ],[
1733                         cf_cv_const_x_string=yes
1734                 ])
1735 ])
1736
1737 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
1738
1739 case "$cf_cv_const_x_string" in
1740 (no)
1741         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
1742         ;;
1743 (*)
1744         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
1745         ;;
1746 esac
1747
1748 ])
1749 ])dnl
1750 dnl ---------------------------------------------------------------------------
1751 dnl CF_CPP_OVERRIDE version: 1 updated: 2022/08/20 16:07:10
1752 dnl ---------------
1753 dnl Check if the C++ compiler accepts the override keyword.  This is a C++-11
1754 dnl feature.
1755 AC_DEFUN([CF_CPP_OVERRIDE],
1756 [
1757 if test -n "$CXX"; then
1758 AC_CACHE_CHECK(if $CXX accepts override keyword,cf_cv_cpp_override,[
1759         AC_LANG_SAVE
1760         AC_LANG_CPLUSPLUS
1761         AC_TRY_RUN([
1762
1763 class base
1764 {
1765 public:
1766         virtual int foo(float x) = 0;
1767 };
1768
1769
1770 class derived: public base
1771 {
1772 public:
1773         int foo(float x) override { return x != 0.0 ? 1 : 0; }
1774 };
1775
1776 int main(void) { }
1777 ],
1778         [cf_cv_cpp_override=yes],
1779         [cf_cv_cpp_override=no],
1780         [cf_cv_cpp_override=unknown])
1781         AC_LANG_RESTORE
1782 ])
1783 fi
1784 test "$cf_cv_cpp_override" = yes && AC_DEFINE(CPP_HAS_OVERRIDE,1,[Define to 1 if C++ has override keyword])
1785 ])dnl
1786 dnl ---------------------------------------------------------------------------
1787 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1788 dnl -----------------
1789 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1790 dnl is a late feature for the standard and is not in some recent compilers
1791 dnl (1999/9/11).
1792 AC_DEFUN([CF_CPP_PARAM_INIT],
1793 [
1794 if test -n "$CXX"; then
1795 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1796         AC_LANG_SAVE
1797         AC_LANG_CPLUSPLUS
1798         AC_TRY_RUN([
1799 class TEST {
1800 private:
1801         int value;
1802 public:
1803         TEST(int x = 1);
1804         ~TEST();
1805 };
1806
1807 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1808 {
1809         value = x;
1810 }
1811 int main(void) { }
1812 ],
1813         [cf_cv_cpp_param_init=yes],
1814         [cf_cv_cpp_param_init=no],
1815         [cf_cv_cpp_param_init=unknown])
1816         AC_LANG_RESTORE
1817 ])
1818 fi
1819 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1820 ])dnl
1821 dnl ---------------------------------------------------------------------------
1822 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1823 dnl ------------------
1824 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1825 dnl not be supported in g++ before 3.0
1826 AC_DEFUN([CF_CPP_STATIC_CAST],
1827 [
1828 if test -n "$CXX"; then
1829
1830 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1831         AC_LANG_SAVE
1832         AC_LANG_CPLUSPLUS
1833
1834         AC_TRY_COMPILE([
1835 class NCursesPanel
1836 {
1837 public:
1838   NCursesPanel(int nlines,
1839                int ncols,
1840                int begin_y = 0,
1841                int begin_x = 0)
1842   {
1843   }
1844   NCursesPanel();
1845   ~NCursesPanel();
1846 };
1847
1848 template<class T> class NCursesUserPanel : public NCursesPanel
1849 {
1850 public:
1851   NCursesUserPanel (int nlines,
1852                     int ncols,
1853                     int begin_y = 0,
1854                     int begin_x = 0,
1855                     const T* p_UserData = static_cast<T*>(0))
1856     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1857   {
1858   };
1859   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1860   {
1861   };
1862
1863   virtual ~NCursesUserPanel() {};
1864 };
1865 ],[
1866         const char* p_UserData = static_cast<char*>(0)],
1867         [cf_cv_cpp_static_cast=yes],
1868         [cf_cv_cpp_static_cast=no])
1869
1870         AC_LANG_RESTORE
1871 ])
1872
1873 fi
1874
1875 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1876 ])dnl
1877 dnl ---------------------------------------------------------------------------
1878 dnl CF_CXX_AR_FLAGS version: 3 updated: 2021/01/01 13:31:04
1879 dnl ---------------
1880 dnl Setup special archiver flags for given compilers.
1881 AC_DEFUN([CF_CXX_AR_FLAGS],[
1882         CXX_AR='$(AR)'
1883         CXX_ARFLAGS='$(ARFLAGS)'
1884         case "$cf_cv_system_name" in
1885         (irix*)
1886             if test "$GXX" != yes ; then
1887                 CXX_AR='$(CXX)'
1888                 CXX_ARFLAGS='-ar -o'
1889             fi
1890             ;;
1891         (sco3.2v5*)
1892             CXXLDFLAGS="-u main"
1893             ;;
1894         (solaris2*)
1895             if test "$GXX" != yes ; then
1896                 CXX_AR='$(CXX)'
1897                 CXX_ARFLAGS='-xar -o'
1898             fi
1899             ;;
1900         esac
1901         AC_SUBST(CXXLDFLAGS)
1902         AC_SUBST(CXX_AR)
1903         AC_SUBST(CXX_ARFLAGS)
1904 ])dnl
1905 dnl ---------------------------------------------------------------------------
1906 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1907 dnl -------------------------
1908 dnl For c++, check if iostream uses "std::" namespace.
1909 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1910 AC_CHECK_HEADERS(iostream)
1911 if test x"$ac_cv_header_iostream" = xyes ; then
1912         AC_MSG_CHECKING(if iostream uses std-namespace)
1913         AC_TRY_COMPILE([
1914 #include <iostream>
1915 using std::endl;
1916 using std::cerr;],[
1917 cerr << "testing" << endl;
1918 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1919         AC_MSG_RESULT($cf_iostream_namespace)
1920         if test "$cf_iostream_namespace" = yes ; then
1921                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1922         fi
1923 fi
1924 ])dnl
1925 dnl ---------------------------------------------------------------------------
1926 dnl CF_C_INLINE version: 6 updated: 2019/09/07 13:38:36
1927 dnl -----------
1928 dnl Check if the C compiler supports "inline".
1929 dnl $1 is the name of a shell variable to set if inline is supported
1930 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1931 AC_DEFUN([CF_C_INLINE],[
1932 AC_REQUIRE([CF_GCC_VERSION])
1933 AC_C_INLINE
1934 $1=
1935 if test "$ac_cv_c_inline" != no ; then
1936         $1=inline
1937         if test "$INTEL_COMPILER" = yes
1938         then
1939                 :
1940         elif test "$CLANG_COMPILER" = yes
1941         then
1942                 :
1943         elif test "$GCC" = yes
1944         then
1945                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1946                 cf_save_CFLAGS=$CFLAGS
1947                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1948                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1949                 [${cf_cv_main_return:-return} foo()],
1950                 [cf_cv_gcc_inline=yes],
1951                 [cf_cv_gcc_inline=no])
1952                 CFLAGS=$cf_save_CFLAGS
1953                 ])
1954                 if test "$cf_cv_gcc_inline" = yes ; then
1955                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1956                 fi
1957         fi
1958 fi
1959 AC_SUBST($1)
1960 ])dnl
1961 dnl ---------------------------------------------------------------------------
1962 dnl CF_DIRNAME version: 5 updated: 2020/12/31 20:19:42
1963 dnl ----------
1964 dnl "dirname" is not portable, so we fake it with a shell script.
1965 AC_DEFUN([CF_DIRNAME],[$1=`echo "$2" | sed -e 's%/[[^/]]*$%%'`])dnl
1966 dnl ---------------------------------------------------------------------------
1967 dnl CF_DIRS_TO_MAKE version: 4 updated: 2021/01/01 13:31:04
1968 dnl ---------------
1969 AC_DEFUN([CF_DIRS_TO_MAKE],
1970 [
1971 DIRS_TO_MAKE="lib"
1972 for cf_item in $cf_list_models
1973 do
1974         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1975         for cf_item2 in $DIRS_TO_MAKE
1976         do
1977                 test "$cf_item2" = "$cf_subdir" && break
1978         done
1979         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1980 done
1981 for cf_dir in $DIRS_TO_MAKE
1982 do
1983         test ! -d "$cf_dir" && mkdir "$cf_dir"
1984 done
1985 AC_SUBST(DIRS_TO_MAKE)
1986 ])dnl
1987 dnl ---------------------------------------------------------------------------
1988 dnl CF_DISABLE_ECHO version: 14 updated: 2021/09/04 06:35:04
1989 dnl ---------------
1990 dnl You can always use "make -n" to see the actual options, but it is hard to
1991 dnl pick out/analyze warning messages when the compile-line is long.
1992 dnl
1993 dnl Sets:
1994 dnl     ECHO_LT - symbol to control if libtool is verbose
1995 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1996 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1997 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1998 dnl     ECHO_CC - symbol to put before any "cc" line
1999 dnl
2000 AC_DEFUN([CF_DISABLE_ECHO],[
2001 AC_MSG_CHECKING(if you want to see long compiling messages)
2002 CF_ARG_DISABLE(echo,
2003         [  --disable-echo          do not display "compiling" commands],
2004         [
2005         ECHO_LT='--silent'
2006         ECHO_LD='@echo linking [$]@;'
2007         RULE_CC='@echo compiling [$]<'
2008         SHOW_CC='@echo compiling [$]@'
2009         ECHO_CC='@'
2010 ],[
2011         ECHO_LT=''
2012         ECHO_LD=''
2013         RULE_CC=''
2014         SHOW_CC=''
2015         ECHO_CC=''
2016 ])
2017 AC_MSG_RESULT($enableval)
2018 AC_SUBST(ECHO_LT)
2019 AC_SUBST(ECHO_LD)
2020 AC_SUBST(RULE_CC)
2021 AC_SUBST(SHOW_CC)
2022 AC_SUBST(ECHO_CC)
2023 ])dnl
2024 dnl ---------------------------------------------------------------------------
2025 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
2026 dnl ------------------------
2027 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
2028 AC_MSG_CHECKING(if we want to use GNAT projects)
2029 CF_ARG_DISABLE(gnat-projects,
2030         [  --disable-gnat-projects test: disable GNAT projects even if usable],
2031         [enable_gnat_projects=no],
2032         [enable_gnat_projects=yes])
2033 AC_MSG_RESULT($enable_gnat_projects)
2034 ])dnl
2035 dnl ---------------------------------------------------------------------------
2036 dnl CF_DISABLE_LEAKS version: 9 updated: 2021/04/03 16:41:50
2037 dnl ----------------
2038 dnl Combine no-leak checks with the libraries or tools that are used for the
2039 dnl checks.
2040 AC_DEFUN([CF_DISABLE_LEAKS],[
2041
2042 AC_REQUIRE([CF_WITH_DMALLOC])
2043 AC_REQUIRE([CF_WITH_DBMALLOC])
2044 AC_REQUIRE([CF_WITH_VALGRIND])
2045
2046 AC_MSG_CHECKING(if you want to perform memory-leak testing)
2047 AC_ARG_ENABLE(leaks,
2048         [  --disable-leaks         test: free permanent memory, analyze leaks],
2049         [enable_leaks=$enableval],
2050         [enable_leaks=yes])
2051 dnl with_no_leaks is more readable...
2052 if test "x$enable_leaks" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi
2053 AC_MSG_RESULT($with_no_leaks)
2054
2055 if test "$enable_leaks" = no ; then
2056         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
2057         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
2058 fi
2059 ])dnl
2060 dnl ---------------------------------------------------------------------------
2061 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
2062 dnl --------------------------
2063 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
2064 dnl the older "-version-info" feature.  The newer feature allows us to use
2065 dnl version numbering on shared libraries which make them compatible with
2066 dnl various systems.
2067 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
2068 [
2069 AC_MSG_CHECKING(if libtool -version-number should be used)
2070 CF_ARG_DISABLE(libtool-version,
2071         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
2072         [cf_libtool_version=no],
2073         [cf_libtool_version=yes])
2074 AC_MSG_RESULT($cf_libtool_version)
2075
2076 if test "$cf_libtool_version" = yes ; then
2077         LIBTOOL_VERSION="-version-number"
2078 else
2079         LIBTOOL_VERSION="-version-info"
2080         case "x$VERSION" in
2081         (x)
2082                 AC_MSG_WARN(VERSION was not set)
2083                 ;;
2084         (x*.*.*)
2085                 ABI_VERSION="$VERSION"
2086                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
2087                 ;;
2088         (x*:*:*)
2089                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
2090                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
2091                 ;;
2092         (*)
2093                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
2094                 ;;
2095         esac
2096 fi
2097
2098 AC_SUBST(ABI_VERSION)
2099 AC_SUBST(LIBTOOL_VERSION)
2100 ])dnl
2101 dnl ---------------------------------------------------------------------------
2102 dnl CF_DISABLE_RPATH_HACK version: 3 updated: 2021/01/05 20:14:44
2103 dnl ---------------------
2104 dnl The rpath-hack makes it simpler to build programs, particularly with the
2105 dnl *BSD ports which may have essential libraries in unusual places.  But it
2106 dnl can interfere with building an executable for the base system.  Use this
2107 dnl option in that case.
2108 AC_DEFUN([CF_DISABLE_RPATH_HACK],
2109 [
2110 AC_MSG_CHECKING(if rpath-hack should be disabled)
2111 CF_ARG_DISABLE(rpath-hack,
2112         [  --disable-rpath-hack    don't add rpath options for additional libraries],
2113         [enable_rpath_hack=no],
2114         [enable_rpath_hack=yes])
2115 dnl TODO - drop cf_disable_rpath_hack
2116 if test "x$enable_rpath_hack" = xno; then cf_disable_rpath_hack=yes; else cf_disable_rpath_hack=no; fi
2117 AC_MSG_RESULT($cf_disable_rpath_hack)
2118
2119 if test "$enable_rpath_hack" = yes ; then
2120         CF_RPATH_HACK
2121 fi
2122 ])
2123 dnl ---------------------------------------------------------------------------
2124 dnl CF_ENABLE_BROKEN_LINKER version: 2 updated: 2021/01/02 17:09:14
2125 dnl -----------------------
2126 dnl Some linkers cannot reference a data-only object.  Cygwin used to be one.
2127 dnl This usually follows CF_LINK_DATAONLY, but is not required in case we need
2128 dnl an unconditional feature.
2129 AC_DEFUN([CF_ENABLE_BROKEN_LINKER],[
2130
2131 AC_MSG_CHECKING(if you want broken-linker support code)
2132 AC_ARG_ENABLE(broken_linker,
2133         [  --enable-broken_linker  compile with broken-linker support code],
2134         [with_broken_linker=$enableval],
2135         [with_broken_linker=no])
2136 AC_MSG_RESULT($with_broken_linker)
2137
2138 : "${BROKEN_LINKER:=0}"
2139 if test "x$with_broken_linker" = xyes ; then
2140         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
2141         BROKEN_LINKER=1
2142 fi
2143 AC_SUBST(BROKEN_LINKER)
2144 ])dnl
2145 dnl ---------------------------------------------------------------------------
2146 dnl CF_ENABLE_PC_FILES version: 16 updated: 2021/11/20 12:48:37
2147 dnl ------------------
2148 dnl This is the "--enable-pc-files" option, which is available if there is a
2149 dnl pkg-config configuration on the local machine.
2150 AC_DEFUN([CF_ENABLE_PC_FILES],[
2151 AC_REQUIRE([CF_PKG_CONFIG])
2152 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
2153
2154 if test "x$PKG_CONFIG" != xnone
2155 then
2156         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
2157 else
2158         AC_MSG_CHECKING(if we should install .pc files)
2159 fi
2160
2161 AC_ARG_ENABLE(pc-files,
2162         [  --enable-pc-files       generate and install .pc files for pkg-config],
2163         [enable_pc_files=$enableval],
2164         [enable_pc_files=no])
2165 AC_MSG_RESULT($enable_pc_files)
2166
2167 if test "x$enable_pc_files" != xno
2168 then
2169         MAKE_PC_FILES=
2170         case "x$PKG_CONFIG_LIBDIR" in
2171         (xno|xnone|xyes|x)
2172                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
2173                 ;;
2174         (*)
2175                 cf_pkg_config_libdir="$PKG_CONFIG_LIBDIR"
2176                 CF_PATH_SYNTAX(cf_pkg_config_libdir)
2177                 ;;
2178         esac
2179 else
2180         MAKE_PC_FILES="#"
2181 fi
2182 AC_SUBST(MAKE_PC_FILES)
2183 ])dnl
2184 dnl ---------------------------------------------------------------------------
2185 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
2186 dnl ---------------
2187 dnl Check if the rpath option should be used, setting cache variable
2188 dnl cf_cv_enable_rpath if so.
2189 AC_DEFUN([CF_ENABLE_RPATH],
2190 [
2191 AC_MSG_CHECKING(if rpath option should be used)
2192 AC_ARG_ENABLE(rpath,
2193 [  --enable-rpath          use rpath option when generating shared libraries],
2194 [cf_cv_enable_rpath=$enableval],
2195 [cf_cv_enable_rpath=no])
2196 AC_MSG_RESULT($cf_cv_enable_rpath)
2197 ])dnl
2198 dnl ---------------------------------------------------------------------------
2199 dnl CF_ENABLE_STRING_HACKS version: 6 updated: 2021/01/05 19:23:48
2200 dnl ----------------------
2201 dnl On a few platforms, the compiler and/or loader nags with untruthful
2202 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
2203 dnl and implying that most uses of the recommended alternatives are correct.
2204 dnl
2205 dnl Factually speaking, no one has actually counted the number of uses of these
2206 dnl functions versus the total of incorrect uses.  Samples of a few thousand
2207 dnl instances are meaningless compared to the hundreds of millions of lines of
2208 dnl existing C code.
2209 dnl
2210 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
2211 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
2212 dnl standard - but evolved through phases, and older implementations are likely
2213 dnl to yield surprising results, as documented in manpages on various systems.
2214 AC_DEFUN([CF_ENABLE_STRING_HACKS],
2215 [
2216 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
2217 AC_ARG_ENABLE(string-hacks,
2218         [  --enable-string-hacks   work around bogus compiler/loader warnings],
2219         [enable_string_hacks=$enableval],
2220         [enable_string_hacks=no])
2221 AC_MSG_RESULT($enable_string_hacks)
2222
2223 if test "x$enable_string_hacks" = "xyes"; then
2224         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
2225         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
2226         AC_CHECK_FUNC(strlcat,[
2227                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2228                 ],[
2229                 AC_CHECK_LIB(bsd,strlcat,[
2230                         CF_ADD_LIB(bsd)
2231                         AC_CHECK_HEADERS(bsd/string.h)
2232                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2233                         ])
2234                 ])
2235         AC_CHECK_FUNCS( strlcpy snprintf )
2236 fi
2237 ])dnl
2238 dnl ---------------------------------------------------------------------------
2239 dnl CF_ENABLE_WARNINGS version: 9 updated: 2021/01/05 19:40:50
2240 dnl ------------------
2241 dnl Configure-option to enable gcc warnings
2242 dnl
2243 dnl $1 = extra options to add, if supported
2244 dnl $2 = option for checking attributes.  By default, this is done when
2245 dnl      warnings are enabled.  For other values:
2246 dnl      yes: always do this, e.g., to use in generated library-headers
2247 dnl      no: never do this
2248 AC_DEFUN([CF_ENABLE_WARNINGS],[
2249 if test "$GCC" = yes || test "$GXX" = yes
2250 then
2251 CF_FIX_WARNINGS(CFLAGS)
2252 CF_FIX_WARNINGS(CPPFLAGS)
2253 CF_FIX_WARNINGS(LDFLAGS)
2254 AC_MSG_CHECKING(if you want to turn on gcc warnings)
2255 CF_ARG_ENABLE(warnings,
2256         [  --enable-warnings       test: turn on gcc compiler warnings],
2257         [enable_warnings=yes],
2258         [enable_warnings=no])
2259 AC_MSG_RESULT($enable_warnings)
2260 if test "$enable_warnings" = "yes"
2261 then
2262         ifelse($2,,[CF_GCC_ATTRIBUTES])
2263         CF_GCC_WARNINGS($1)
2264 fi
2265 ifelse($2,yes,[CF_GCC_ATTRIBUTES])
2266 fi
2267 ])dnl
2268 dnl ---------------------------------------------------------------------------
2269 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
2270 dnl --------
2271 dnl Check if 'errno' is declared in <errno.h>
2272 AC_DEFUN([CF_ERRNO],
2273 [
2274 CF_CHECK_ERRNO(errno)
2275 ])dnl
2276 dnl ---------------------------------------------------------------------------
2277 dnl CF_ETIP_DEFINES version: 7 updated: 2023/10/28 11:59:01
2278 dnl ---------------
2279 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
2280 dnl math.h and builtin.h, only for ncurses
2281 AC_DEFUN([CF_ETIP_DEFINES],
2282 [
2283 AC_MSG_CHECKING(for special defines needed for etip.h)
2284 cf_save_CXXFLAGS="$CXXFLAGS"
2285 cf_result="none"
2286
2287 # etip.h includes ncurses.h which includes ncurses_dll.h
2288 # But ncurses_dll.h is generated - fix here.
2289 test -d include || mkdir include
2290 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' "${srcdir}/include/ncurses_dll.h.in" >include/ncurses_dll.h
2291
2292 for cf_math in "" MATH_H
2293 do
2294 for cf_excp in "" MATH_EXCEPTION
2295 do
2296         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
2297         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
2298         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
2299 AC_TRY_COMPILE([
2300 #include <etip.h.in>
2301 ],[],[
2302         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
2303         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
2304         cf_result="$cf_math $cf_excp"
2305         break 2
2306 ],[])
2307 done
2308 done
2309 AC_MSG_RESULT([${cf_result:-(none)}])
2310 CXXFLAGS="$cf_save_CXXFLAGS"
2311 ])
2312 dnl ---------------------------------------------------------------------------
2313 dnl CF_FIND_LINKAGE version: 22 updated: 2020/12/31 20:19:42
2314 dnl ---------------
2315 dnl Find a library (specifically the linkage used in the code fragment),
2316 dnl searching for it if it is not already in the library path.
2317 dnl See also CF_ADD_SEARCHPATH.
2318 dnl
2319 dnl Parameters (4-on are optional):
2320 dnl     $1 = headers for library entrypoint
2321 dnl     $2 = code fragment for library entrypoint
2322 dnl     $3 = the library name without the "-l" option or ".so" suffix.
2323 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
2324 dnl     $5 = action to perform if not successful
2325 dnl     $6 = module name, if not the same as the library name
2326 dnl     $7 = extra libraries
2327 dnl
2328 dnl Sets these variables:
2329 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
2330 dnl     $cf_cv_header_path_$3 - include-directory if needed
2331 dnl     $cf_cv_library_path_$3 - library-directory if needed
2332 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
2333 AC_DEFUN([CF_FIND_LINKAGE],[
2334
2335 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
2336 # will be set on completion of the AC_TRY_LINK below.
2337 cf_cv_header_path_$3=
2338 cf_cv_library_path_$3=
2339
2340 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
2341
2342 cf_save_LIBS="$LIBS"
2343
2344 AC_TRY_LINK([$1],[$2],[
2345         cf_cv_find_linkage_$3=yes
2346         cf_cv_header_path_$3=/usr/include
2347         cf_cv_library_path_$3=/usr/lib
2348 ],[
2349
2350 LIBS="-l$3 $7 $cf_save_LIBS"
2351
2352 AC_TRY_LINK([$1],[$2],[
2353         cf_cv_find_linkage_$3=yes
2354         cf_cv_header_path_$3=/usr/include
2355         cf_cv_library_path_$3=/usr/lib
2356         cf_cv_library_file_$3="-l$3"
2357 ],[
2358         cf_cv_find_linkage_$3=no
2359         LIBS="$cf_save_LIBS"
2360
2361         CF_VERBOSE(find linkage for $3 library)
2362         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
2363
2364         cf_save_CPPFLAGS="$CPPFLAGS"
2365         cf_test_CPPFLAGS="$CPPFLAGS"
2366
2367         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
2368         for cf_cv_header_path_$3 in $cf_search
2369         do
2370                 if test -d "$cf_cv_header_path_$3" ; then
2371                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
2372                         CPPFLAGS="$cf_save_CPPFLAGS"
2373                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
2374                         AC_TRY_COMPILE([$1],[$2],[
2375                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
2376                                 cf_cv_find_linkage_$3=maybe
2377                                 cf_test_CPPFLAGS="$CPPFLAGS"
2378                                 break],[
2379                                 CPPFLAGS="$cf_save_CPPFLAGS"
2380                                 ])
2381                 fi
2382         done
2383
2384         if test "$cf_cv_find_linkage_$3" = maybe ; then
2385
2386                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
2387
2388                 cf_save_LIBS="$LIBS"
2389                 cf_save_LDFLAGS="$LDFLAGS"
2390
2391                 ifelse([$6],,,[
2392                 CPPFLAGS="$cf_test_CPPFLAGS"
2393                 LIBS="-l$3 $7 $cf_save_LIBS"
2394                 AC_TRY_LINK([$1],[$2],[
2395                         CF_VERBOSE(... found $3 library in system)
2396                         cf_cv_find_linkage_$3=yes])
2397                         CPPFLAGS="$cf_save_CPPFLAGS"
2398                         LIBS="$cf_save_LIBS"
2399                         ])
2400
2401                 if test "$cf_cv_find_linkage_$3" != yes ; then
2402                         CF_LIBRARY_PATH(cf_search,$3)
2403                         for cf_cv_library_path_$3 in $cf_search
2404                         do
2405                                 if test -d "$cf_cv_library_path_$3" ; then
2406                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
2407                                         CPPFLAGS="$cf_test_CPPFLAGS"
2408                                         LIBS="-l$3 $7 $cf_save_LIBS"
2409                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
2410                                         AC_TRY_LINK([$1],[$2],[
2411                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
2412                                         cf_cv_find_linkage_$3=yes
2413                                         cf_cv_library_file_$3="-l$3"
2414                                         break],[
2415                                         CPPFLAGS="$cf_save_CPPFLAGS"
2416                                         LIBS="$cf_save_LIBS"
2417                                         LDFLAGS="$cf_save_LDFLAGS"
2418                                         ])
2419                                 fi
2420                         done
2421                         CPPFLAGS="$cf_save_CPPFLAGS"
2422                         LDFLAGS="$cf_save_LDFLAGS"
2423                 fi
2424
2425         else
2426                 cf_cv_find_linkage_$3=no
2427         fi
2428         ],$7)
2429 ])
2430
2431 LIBS="$cf_save_LIBS"
2432
2433 if test "$cf_cv_find_linkage_$3" = yes ; then
2434 ifelse([$4],,[
2435         CF_ADD_INCDIR($cf_cv_header_path_$3)
2436         CF_ADD_LIBDIR($cf_cv_library_path_$3)
2437         CF_ADD_LIB($3)
2438 ],[$4])
2439 else
2440 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
2441 fi
2442 ])dnl
2443 dnl ---------------------------------------------------------------------------
2444 dnl CF_FIND_SUB_INCDIR version: 3 updated: 2021/01/01 13:31:04
2445 dnl ------------------
2446 dnl Find an include-directory with the given leaf-name.  This is useful for
2447 dnl example with FreeBSD ports, which use this convention to distinguish
2448 dnl different versions of the same port.
2449 AC_DEFUN([CF_FIND_SUB_INCDIR],[
2450         CF_SUBDIR_PATH(cf_search,$1,include)
2451         for cf_item in $cf_search
2452         do
2453                 case "$cf_item" in
2454                 (*/$1)
2455                         CF_ADD_INCDIR($cf_item)
2456                         ;;
2457                 esac
2458         done
2459 ])dnl
2460 dnl ---------------------------------------------------------------------------
2461 dnl CF_FIND_SUB_LIBDIR version: 3 updated: 2021/01/01 13:31:04
2462 dnl ------------------
2463 dnl Find a library-directory with the given leaf-name.  This is useful for
2464 dnl example with FreeBSD ports, which use this convention to distinguish
2465 dnl different versions of the same port.
2466 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
2467         CF_SUBDIR_PATH(cf_search,$1,lib)
2468         for cf_item in $cf_search
2469         do
2470                 case "$cf_item" in
2471                 (*/$1)
2472                         CF_ADD_LIBDIR($cf_item)
2473                         ;;
2474                 esac
2475         done
2476 ])dnl
2477 dnl ---------------------------------------------------------------------------
2478 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
2479 dnl -----------------
2480 dnl make ADAFLAGS consistent with CFLAGS
2481 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
2482         AC_MSG_CHECKING(optimization options for ADAFLAGS)
2483         case "$CFLAGS" in
2484         (*-g*)
2485                 CF_ADD_ADAFLAGS(-g)
2486                 ;;
2487         esac
2488         case "$CFLAGS" in
2489         (*-O*)
2490                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
2491                 CF_ADD_ADAFLAGS($cf_O_flag)
2492                 ;;
2493         esac
2494         AC_MSG_RESULT($ADAFLAGS)
2495 ])dnl
2496 dnl ---------------------------------------------------------------------------
2497 dnl CF_FIX_WARNINGS version: 4 updated: 2021/12/16 18:22:31
2498 dnl ---------------
2499 dnl Warning flags do not belong in CFLAGS, CPPFLAGS, etc.  Any of gcc's
2500 dnl "-Werror" flags can interfere with configure-checks.  Those go into
2501 dnl EXTRA_CFLAGS.
2502 dnl
2503 dnl $1 = variable name to repair
2504 define([CF_FIX_WARNINGS],[
2505 if test "$GCC" = yes || test "$GXX" = yes
2506 then
2507         case [$]$1 in
2508         (*-Werror=*)
2509                 cf_temp_flags=
2510                 for cf_temp_scan in [$]$1
2511                 do
2512                         case "x$cf_temp_scan" in
2513                         (x-Werror=format*)
2514                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
2515                                 ;;
2516                         (x-Werror=*)
2517                                 CF_APPEND_TEXT(EXTRA_CFLAGS,$cf_temp_scan)
2518                                 ;;
2519                         (*)
2520                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
2521                                 ;;
2522                         esac
2523                 done
2524                 if test "x[$]$1" != "x$cf_temp_flags"
2525                 then
2526                         CF_VERBOSE(repairing $1: [$]$1)
2527                         $1="$cf_temp_flags"
2528                         CF_VERBOSE(... fixed [$]$1)
2529                         CF_VERBOSE(... extra $EXTRA_CFLAGS)
2530                 fi
2531                 ;;
2532         esac
2533 fi
2534 AC_SUBST(EXTRA_CFLAGS)
2535 ])dnl
2536 dnl ---------------------------------------------------------------------------
2537 dnl CF_FOPEN_BIN_R version: 3 updated: 2023/01/05 18:05:46
2538 dnl --------------
2539 dnl Check if fopen works when the "b" (binary) flag is added to the mode
2540 dnl parameter.  POSIX ignores the "b", which c89 specified.  Some very old
2541 dnl systems do not accept it.
2542 AC_DEFUN([CF_FOPEN_BIN_R],[
2543 AC_CACHE_CHECK(if fopen accepts explicit binary mode,cf_cv_fopen_bin_r,[
2544         AC_TRY_RUN([
2545 $ac_includes_default
2546
2547 int main(void)
2548 {
2549         FILE *fp = fopen("conftest.tmp", "wb");
2550         int rc = 0;
2551         if (fp != 0) {
2552                 int p, q;
2553                 for (p = 0; p < 256; ++p) {
2554                         fputc(p, fp);
2555                 }
2556                 fclose(fp);
2557                 fp = fopen("conftest.tmp", "rb");
2558                 if (fp != 0) {
2559                         for (p = 0; p < 256; ++p) {
2560                                 q = fgetc(fp);
2561                                 if (q != p) {
2562                                         rc = 1;
2563                                         break;
2564                                 }
2565                         }
2566                 } else {
2567                         rc = 1;
2568                 }
2569         } else {
2570                 rc = 1;
2571         }
2572         ${cf_cv_main_return:-return} (rc);
2573 }
2574 ],
2575                 [cf_cv_fopen_bin_r=yes],
2576                 [cf_cv_fopen_bin_r=no],
2577                 [cf_cv_fopen_bin_r=unknown])
2578 ])
2579 test "x$cf_cv_fopen_bin_r" != xno && AC_DEFINE(USE_FOPEN_BIN_R,1,[Define to 1 if fopen accepts explicit binary mode])
2580 ])dnl
2581 dnl ---------------------------------------------------------------------------
2582 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
2583 dnl --------------
2584 dnl Forget that we saw the given tool.
2585 AC_DEFUN([CF_FORGET_TOOL],[
2586 unset ac_cv_prog_ac_ct_$1
2587 unset ac_ct_$1
2588 unset $1
2589 ])dnl
2590 dnl ---------------------------------------------------------------------------
2591 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
2592 dnl -------------
2593 dnl Test for dlsym() and related functions, as well as libdl.
2594 dnl
2595 dnl Sets
2596 dnl     $cf_have_dlsym
2597 dnl     $cf_have_libdl
2598 AC_DEFUN([CF_FUNC_DLSYM],[
2599 cf_have_dlsym=no
2600 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
2601
2602 cf_have_libdl=no
2603 AC_CHECK_LIB(dl,dlsym,[
2604         cf_have_dlsym=yes
2605         cf_have_libdl=yes])])
2606
2607 if test "$cf_have_dlsym" = yes ; then
2608         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
2609
2610         AC_MSG_CHECKING(whether able to link to dl*() functions)
2611         AC_TRY_LINK([#include <dlfcn.h>],[
2612                 void *obj;
2613                 if ((obj = dlopen("filename", 0)) != 0) {
2614                         if (dlsym(obj, "symbolname") == 0) {
2615                         dlclose(obj);
2616                         }
2617                 }],[
2618                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
2619                 AC_MSG_ERROR(Cannot link test program for libdl)])
2620         AC_MSG_RESULT(ok)
2621 else
2622         AC_MSG_ERROR(Cannot find dlsym function)
2623 fi
2624 ])
2625 dnl ---------------------------------------------------------------------------
2626 dnl CF_FUNC_GETTIME version: 2 updated: 2023/02/25 08:45:56
2627 dnl ---------------
2628 dnl Check for gettimeofday or clock_gettime.  In 2023, the former is still more
2629 dnl widely supported, but "deprecated" (2008), so we will use the latter if it
2630 dnl is available, to reduce compiler warnings.
2631 AC_DEFUN([CF_FUNC_GETTIME],[
2632 AC_CACHE_CHECK(for clock_gettime,cf_cv_func_clock_gettime,[
2633                 AC_TRY_LINK([#include <time.h>],
2634                 [struct timespec ts;
2635                 int rc = clock_gettime(CLOCK_REALTIME, &ts); (void) rc; (void)ts],
2636                 [cf_cv_func_clock_gettime=yes],
2637                 [cf_cv_func_clock_gettime=no])
2638 ])
2639
2640 if test "$cf_cv_func_clock_gettime" = yes
2641 then
2642         AC_DEFINE(HAVE_CLOCK_GETTIME,1,[Define to 1 if we have clock_gettime function])
2643 else
2644 AC_CHECK_FUNC(gettimeofday,
2645         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
2646
2647 AC_CHECK_LIB(bsd, gettimeofday,
2648         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
2649         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
2650 fi
2651 ])dnl
2652 dnl ---------------------------------------------------------------------------
2653 dnl CF_FUNC_GETTTYNAM version: 2 updated: 2023/01/05 18:06:28
2654 dnl -----------------
2655 dnl Check if the 4.3BSD function getttyname exists, as well as if <ttyent.h>
2656 dnl defines the _PATH_TTYS symbol.  If the corresponding file exists, but the
2657 dnl other checks fail, just define HAVE_PATH_TTYS.
2658 AC_DEFUN([CF_FUNC_GETTTYNAM],[
2659 AC_CACHE_CHECK(if _PATH_TTYS is defined in ttyent.h,cf_cv_PATH_TTYS,[
2660 AC_TRY_COMPILE([
2661 #include <stdio.h>
2662 #include <ttyent.h>],[
2663 FILE *fp = fopen(_PATH_TTYS, "r"); (void)fp],
2664         [cf_cv_PATH_TTYS=yes],
2665         [cf_cv_PATH_TTYS=no])])
2666
2667 if test $cf_cv_PATH_TTYS = no
2668 then
2669         for cf_ttys in /etc/ttytype /etc/ttys
2670         do
2671                 if test -f $cf_ttys
2672                 then
2673                         cf_cv_PATH_TTYS=maybe
2674                         AC_DEFINE(_PATH_TTYS,$cf_ttys,[define to pathname of file containing mapping from tty name to terminal type])
2675                         break
2676                 fi
2677         done
2678 fi
2679
2680 if test $cf_cv_PATH_TTYS != no
2681 then
2682         AC_CACHE_CHECK(if _PATH_TTYS file exists,cf_cv_have_PATH_TTYS,[
2683                 AC_TRY_RUN([
2684 $ac_includes_default
2685
2686 #include <ttyent.h>
2687
2688 int main(void) {
2689         FILE *fp = fopen(_PATH_TTYS, "r");
2690         ${cf_cv_main_return:-return} (fp == 0);
2691 }],
2692                         [cf_cv_have_PATH_TTYS=yes],
2693                         [cf_cv_have_PATH_TTYS=no],
2694                         [cf_cv_have_PATH_TTYS=unknown])])
2695         test "$cf_cv_have_PATH_TTYS" = no && cf_cv_PATH_TTYS=no
2696 fi
2697
2698 if test $cf_cv_PATH_TTYS != no
2699 then
2700         AC_DEFINE(HAVE_PATH_TTYS,1,[define to 1 if system can map tty name to terminal type])
2701         AC_CACHE_CHECK(for getttynam,cf_cv_func_getttynam,[
2702                 AC_TRY_LINK([#include <ttyent.h>],
2703                 [struct ttyent *fp = getttynam("/dev/tty"); (void)fp],
2704                 [cf_cv_func_getttynam=yes],
2705                 [cf_cv_func_getttynam=no])])
2706         test "$cf_cv_func_getttynam" = yes && AC_DEFINE(HAVE_GETTTYNAM)
2707 fi
2708 ])dnl
2709 dnl ---------------------------------------------------------------------------
2710 dnl CF_FUNC_MEMMOVE version: 10 updated: 2023/01/05 18:51:28
2711 dnl ---------------
2712 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
2713 dnl is found, add our own version of memmove to the list of objects.
2714 AC_DEFUN([CF_FUNC_MEMMOVE],
2715 [
2716 AC_CHECK_FUNC(memmove,,[
2717 AC_CHECK_FUNC(bcopy,[
2718         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
2719                 AC_TRY_RUN([
2720 $ac_includes_default
2721
2722 int main(void) {
2723         static char data[] = "abcdefghijklmnopqrstuwwxyz";
2724         char temp[40];
2725         bcopy(data, temp, sizeof(data));
2726         bcopy(temp+10, temp, 15);
2727         bcopy(temp+5, temp+15, 10);
2728         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
2729 }
2730                 ],
2731                 [cf_cv_good_bcopy=yes],
2732                 [cf_cv_good_bcopy=no],
2733                 [cf_cv_good_bcopy=unknown])
2734                 ])
2735         ],[cf_cv_good_bcopy=no])
2736         if test "$cf_cv_good_bcopy" = yes ; then
2737                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
2738         else
2739                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
2740         fi
2741 ])])dnl
2742 dnl ---------------------------------------------------------------------------
2743 dnl CF_FUNC_NANOSLEEP version: 6 updated: 2023/01/05 18:51:33
2744 dnl -----------------
2745 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
2746 dnl AIX 4.x, provide a non-working version.
2747 AC_DEFUN([CF_FUNC_NANOSLEEP],[
2748 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
2749 AC_TRY_RUN([
2750 $ac_includes_default
2751
2752 #include <errno.h>
2753 #include <time.h>
2754
2755 #ifdef HAVE_SYS_TIME_H
2756 #include <sys/time.h>
2757 #endif
2758
2759 int main(void) {
2760         struct timespec ts1, ts2;
2761         int code;
2762         ts1.tv_sec  = 0;
2763         ts1.tv_nsec = 750000000;
2764         ts2.tv_sec  = 0;
2765         ts2.tv_nsec = 0;
2766         errno = 0;
2767         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
2768         ${cf_cv_main_return:-return}(code != 0);
2769 }
2770 ],
2771         [cf_cv_func_nanosleep=yes],
2772         [cf_cv_func_nanosleep=no],
2773         [cf_cv_func_nanosleep=unknown])])
2774
2775 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
2776 ])
2777 dnl ---------------------------------------------------------------------------
2778 dnl CF_FUNC_OPENPTY version: 7 updated: 2023/12/03 09:21:34
2779 dnl ---------------
2780 dnl Check for openpty() function, along with <pty.h> header.  It may need the
2781 dnl "util" library as well.
2782 AC_DEFUN([CF_FUNC_OPENPTY],
2783 [
2784 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
2785 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
2786         cf_save_LIBS="$LIBS"
2787         test "$cf_cv_lib_util" = yes && { CF_ADD_LIB(util) }
2788         for cf_header in pty.h libutil.h util.h
2789         do
2790         AC_TRY_LINK([
2791 #include <$cf_header>
2792 ],[
2793         int x = openpty((int *)0, (int *)0, (char *)0,
2794                                    (struct termios *)0, (struct winsize *)0);
2795         (void)x;
2796 ],[
2797                 cf_cv_func_openpty=$cf_header
2798                 break
2799 ],[
2800                 cf_cv_func_openpty=no
2801 ])
2802         done
2803         LIBS="$cf_save_LIBS"
2804 ])
2805 ])dnl
2806 dnl ---------------------------------------------------------------------------
2807 dnl CF_FUNC_POLL version: 11 updated: 2023/01/05 18:51:40
2808 dnl ------------
2809 dnl See if the poll function really works.  Some platforms have poll(), but
2810 dnl it does not work for terminals or files.
2811 AC_DEFUN([CF_FUNC_POLL],[
2812 tty >/dev/null 2>&1 || { AC_CHECK_FUNCS(posix_openpt) }
2813 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2814 AC_TRY_RUN([
2815 $ac_includes_default
2816
2817 #include <fcntl.h>
2818
2819 #ifdef HAVE_POLL_H
2820 #include <poll.h>
2821 #else
2822 #include <sys/poll.h>
2823 #endif
2824
2825 int main(void) {
2826         struct pollfd myfds;
2827         int ret;
2828
2829         /* check for Darwin bug with respect to "devices" */
2830         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2831         if (myfds.fd < 0)
2832                 myfds.fd = 0;
2833         myfds.events = POLLIN;
2834         myfds.revents = 0;
2835
2836         ret = poll(&myfds, 1, 100);
2837
2838         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2839                 ret = -1;
2840         } else {
2841                 int fd = 0;
2842                 if (!isatty(fd)) {
2843                         fd = open("/dev/tty", 2);       /* O_RDWR */
2844                 }
2845 #ifdef HAVE_POSIX_OPENPT
2846                 if (fd < 0) {
2847                         fd = posix_openpt(O_RDWR);
2848                 }
2849 #endif
2850
2851                 if (fd >= 0) {
2852                         /* also check with standard input */
2853                         myfds.fd = fd;
2854                         myfds.events = POLLIN;
2855                         myfds.revents = 0;
2856                         ret = poll(&myfds, 1, 100);
2857                 } else {
2858                         ret = -1;
2859                 }
2860         }
2861         ${cf_cv_main_return:-return}(ret < 0);
2862 }],
2863         [cf_cv_working_poll=yes],
2864         [cf_cv_working_poll=no],
2865         [cf_cv_working_poll=unknown])])
2866 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2867 ])dnl
2868 dnl ---------------------------------------------------------------------------
2869 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2870 dnl ---------------
2871 dnl Some old/broken variations define tcgetattr() only as a macro in
2872 dnl termio(s).h
2873 AC_DEFUN([CF_FUNC_TERMIOS],[
2874 AC_REQUIRE([CF_STRUCT_TERMIOS])
2875 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2876 AC_TRY_LINK([
2877 #include <sys/types.h>
2878 #ifdef HAVE_UNISTD_H
2879 #include <unistd.h>
2880 #endif
2881 #ifdef HAVE_TERMIOS_H
2882 #include <termios.h>
2883 #define TTY struct termios
2884 #else
2885 #ifdef HAVE_TERMIO_H
2886 #include <termio.h>
2887 #define TTY struct termio
2888 #endif
2889 #endif
2890 ],[
2891 TTY foo;
2892 tcgetattr(1, &foo);],
2893 [cf_cv_have_tcgetattr=yes],
2894 [cf_cv_have_tcgetattr=no])])
2895 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2896 ])dnl
2897 dnl ---------------------------------------------------------------------------
2898 dnl CF_FUNC_VSSCANF version: 8 updated: 2023/12/03 19:09:59
2899 dnl ---------------
2900 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2901 dnl versions of C.  It can often be simulated by other functions on older
2902 dnl systems (where FILE is not opaque).
2903 AC_DEFUN([CF_FUNC_VSSCANF],
2904 [
2905 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2906 AC_TRY_LINK([
2907 #include <stdarg.h>
2908 #include <stdio.h>
2909
2910 static void
2911 myfunc(const char *str, const char *fmt, ...)
2912 {
2913         va_list ap;
2914         va_start(ap, fmt);
2915         vsscanf(str, fmt, ap);
2916         va_end(ap);
2917 }
2918 ],[
2919         myfunc("55", "%d");
2920 ],[cf_cv_func_vsscanf=vsscanf],[
2921 AC_TRY_LINK([
2922 #include <stdarg.h>
2923 #include <stdio.h>],[
2924         FILE strbuf;
2925         char *str = "from";
2926
2927         strbuf._flag = _IOREAD;
2928         strbuf._ptr = strbuf._base = (unsigned char *) str;
2929         strbuf._cnt = strlen(str);
2930         strbuf._file = _NFILE;
2931         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2932 AC_TRY_LINK([
2933 #include <stdarg.h>
2934 #include <stdio.h>],[
2935         FILE strbuf;
2936         char *str = "from";
2937
2938         strbuf._flag = _IOREAD;
2939         strbuf._ptr = strbuf._base = (unsigned char *) str;
2940         strbuf._cnt = strlen(str);
2941         strbuf._file = _NFILE;
2942         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2943 cf_cv_func_vsscanf=no])])])])
2944
2945 case "$cf_cv_func_vsscanf" in
2946 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2947 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2948 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2949 esac
2950
2951 ])dnl
2952 dnl ---------------------------------------------------------------------------
2953 dnl CF_GCC_ATTRIBUTES version: 24 updated: 2021/03/20 12:00:25
2954 dnl -----------------
2955 dnl Test for availability of useful gcc __attribute__ directives to quiet
2956 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2957 dnl to documentation, unrecognized directives cause older compilers to barf.
2958 AC_DEFUN([CF_GCC_ATTRIBUTES],
2959 [AC_REQUIRE([AC_PROG_FGREP])dnl
2960 AC_REQUIRE([CF_C11_NORETURN])dnl
2961
2962 if test "$GCC" = yes || test "$GXX" = yes
2963 then
2964 cat > conftest.i <<EOF
2965 #ifndef GCC_PRINTF
2966 #define GCC_PRINTF 0
2967 #endif
2968 #ifndef GCC_SCANF
2969 #define GCC_SCANF 0
2970 #endif
2971 #ifndef GCC_NORETURN
2972 #define GCC_NORETURN /* nothing */
2973 #endif
2974 #ifndef GCC_UNUSED
2975 #define GCC_UNUSED /* nothing */
2976 #endif
2977 EOF
2978 if test "$GCC" = yes
2979 then
2980         AC_CHECKING([for $CC __attribute__ directives])
2981 cat > "conftest.$ac_ext" <<EOF
2982 #line __oline__ "${as_me:-configure}"
2983 #include <stdio.h>
2984 #include "confdefs.h"
2985 #include "conftest.h"
2986 #include "conftest.i"
2987 #if     GCC_PRINTF
2988 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2989 #else
2990 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2991 #endif
2992 #if     GCC_SCANF
2993 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2994 #else
2995 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2996 #endif
2997 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2998 extern GCC_NORETURN void oops(char *,...) GCC_PRINTFLIKE(1,2);
2999 extern GCC_NORETURN void foo(void);
3000 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
3001 EOF
3002         cf_printf_attribute=no
3003         cf_scanf_attribute=no
3004         for cf_attribute in scanf printf unused noreturn
3005         do
3006                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
3007                 cf_directive="__attribute__(($cf_attribute))"
3008                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
3009
3010                 case "$cf_attribute" in
3011                 (printf)
3012                         cf_printf_attribute=yes
3013                         cat >conftest.h <<EOF
3014 #define GCC_$cf_ATTRIBUTE 1
3015 EOF
3016                         ;;
3017                 (scanf)
3018                         cf_scanf_attribute=yes
3019                         cat >conftest.h <<EOF
3020 #define GCC_$cf_ATTRIBUTE 1
3021 EOF
3022                         ;;
3023                 (*)
3024                         cat >conftest.h <<EOF
3025 #define GCC_$cf_ATTRIBUTE $cf_directive
3026 EOF
3027                         ;;
3028                 esac
3029
3030                 if AC_TRY_EVAL(ac_compile); then
3031                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
3032                         cat conftest.h >>confdefs.h
3033                         case "$cf_attribute" in
3034                         (noreturn)
3035                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
3036                                 ;;
3037                         (printf)
3038                                 cf_value='/* nothing */'
3039                                 if test "$cf_printf_attribute" != no ; then
3040                                         cf_value='__attribute__((format(printf,fmt,var)))'
3041                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
3042                                 fi
3043                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
3044                                 ;;
3045                         (scanf)
3046                                 cf_value='/* nothing */'
3047                                 if test "$cf_scanf_attribute" != no ; then
3048                                         cf_value='__attribute__((format(scanf,fmt,var)))'
3049                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
3050                                 fi
3051                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
3052                                 ;;
3053                         (unused)
3054                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
3055                                 ;;
3056                         esac
3057                 fi
3058         done
3059 else
3060         ${FGREP-fgrep} define conftest.i >>confdefs.h
3061 fi
3062 rm -rf ./conftest*
3063 fi
3064 ])dnl
3065 dnl ---------------------------------------------------------------------------
3066 dnl CF_GCC_VERSION version: 9 updated: 2023/03/05 14:30:13
3067 dnl --------------
3068 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
3069 dnl compatible), attempt to determine if icc/clang is actually used.
3070 AC_DEFUN([CF_GCC_VERSION],[
3071 AC_REQUIRE([AC_PROG_CC])
3072 GCC_VERSION=none
3073 if test "$GCC" = yes ; then
3074         AC_MSG_CHECKING(version of $CC)
3075         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^[[^(]]*([[^)]][[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
3076         test -z "$GCC_VERSION" && GCC_VERSION=unknown
3077         AC_MSG_RESULT($GCC_VERSION)
3078 fi
3079 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
3080 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
3081 ])dnl
3082 dnl ---------------------------------------------------------------------------
3083 dnl CF_GCC_WARNINGS version: 41 updated: 2021/01/01 16:53:59
3084 dnl ---------------
3085 dnl Check if the compiler supports useful warning options.  There's a few that
3086 dnl we don't use, simply because they're too noisy:
3087 dnl
3088 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
3089 dnl     -Winline (usually not worthwhile)
3090 dnl     -Wredundant-decls (system headers make this too noisy)
3091 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
3092 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
3093 dnl             is enabled for ncurses using "--enable-const".
3094 dnl     -pedantic
3095 dnl
3096 dnl Parameter:
3097 dnl     $1 is an optional list of gcc warning flags that a particular
3098 dnl             application might want to use, e.g., "no-unused" for
3099 dnl             -Wno-unused
3100 dnl Special:
3101 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
3102 dnl
3103 AC_DEFUN([CF_GCC_WARNINGS],
3104 [
3105 AC_REQUIRE([CF_GCC_VERSION])
3106 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
3107 cat > "conftest.$ac_ext" <<EOF
3108 #line __oline__ "${as_me:-configure}"
3109 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
3110 EOF
3111 if test "$INTEL_COMPILER" = yes
3112 then
3113 # The "-wdXXX" options suppress warnings:
3114 # remark #1419: external declaration in primary source file
3115 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3116 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
3117 # remark #193: zero used for undefined preprocessing identifier
3118 # remark #593: variable "curs_sb_left_arrow" was set but never used
3119 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
3120 # remark #869: parameter "tw" was never referenced
3121 # remark #981: operands are evaluated in unspecified order
3122 # warning #279: controlling expression is constant
3123
3124         AC_CHECKING([for $CC warning options])
3125         cf_save_CFLAGS="$CFLAGS"
3126         EXTRA_CFLAGS="$EXTRA_CFLAGS -Wall"
3127         for cf_opt in \
3128                 wd1419 \
3129                 wd1683 \
3130                 wd1684 \
3131                 wd193 \
3132                 wd593 \
3133                 wd279 \
3134                 wd810 \
3135                 wd869 \
3136                 wd981
3137         do
3138                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
3139                 if AC_TRY_EVAL(ac_compile); then
3140                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3141                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
3142                 fi
3143         done
3144         CFLAGS="$cf_save_CFLAGS"
3145 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
3146 then
3147         AC_CHECKING([for $CC warning options])
3148         cf_save_CFLAGS="$CFLAGS"
3149         cf_warn_CONST=""
3150         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
3151         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
3152         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
3153         for cf_opt in W Wall \
3154                 Wbad-function-cast \
3155                 Wcast-align \
3156                 Wcast-qual \
3157                 Wdeclaration-after-statement \
3158                 Wextra \
3159                 Winline \
3160                 Wmissing-declarations \
3161                 Wmissing-prototypes \
3162                 Wnested-externs \
3163                 Wpointer-arith \
3164                 Wshadow \
3165                 Wstrict-prototypes \
3166                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
3167         do
3168                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
3169                 if AC_TRY_EVAL(ac_compile); then
3170                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3171                         case "$cf_opt" in
3172                         (Winline)
3173                                 case "$GCC_VERSION" in
3174                                 ([[34]].*)
3175                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
3176                                         continue;;
3177                                 esac
3178                                 ;;
3179                         (Wpointer-arith)
3180                                 case "$GCC_VERSION" in
3181                                 ([[12]].*)
3182                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
3183                                         continue;;
3184                                 esac
3185                                 ;;
3186                         esac
3187                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
3188                 fi
3189         done
3190         CFLAGS="$cf_save_CFLAGS"
3191 fi
3192 rm -rf ./conftest*
3193
3194 AC_SUBST(EXTRA_CFLAGS)
3195 ])dnl
3196 dnl ---------------------------------------------------------------------------
3197 dnl CF_GETOPT_HEADER version: 8 updated: 2021/06/19 19:16:16
3198 dnl ----------------
3199 dnl Check for getopt's variables which are commonly defined in stdlib.h,
3200 dnl unistd.h or (nonstandard) in getopt.h
3201 AC_DEFUN([CF_GETOPT_HEADER],
3202 [
3203 AC_HAVE_HEADERS(unistd.h getopt.h)
3204 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
3205 cf_cv_getopt_header=none
3206 for cf_header in stdio.h stdlib.h unistd.h getopt.h
3207 do
3208 AC_TRY_COMPILE([
3209 #include <$cf_header>],
3210 [int x = optind; char *y = optarg; (void)x; (void)y],
3211 [cf_cv_getopt_header=$cf_header
3212  break])
3213 done
3214 ])
3215 if test "$cf_cv_getopt_header" != none ; then
3216         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
3217 fi
3218 if test "$cf_cv_getopt_header" = getopt.h ; then
3219         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
3220 fi
3221 ])dnl
3222 dnl ---------------------------------------------------------------------------
3223 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
3224 dnl -----------------
3225 AC_DEFUN([CF_GNATPREP_OPT_T],[
3226 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
3227 cf_cv_gnatprep_opt_t=no
3228 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
3229 ])
3230 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
3231 AC_SUBST(GNATPREP_OPTS)
3232 ])dnl
3233 dnl ---------------------------------------------------------------------------
3234 dnl CF_GNAT_GENERICS version: 7 updated: 2021/01/01 13:31:04
3235 dnl ----------------
3236 AC_DEFUN([CF_GNAT_GENERICS],
3237 [
3238 AC_REQUIRE([CF_GNAT_VERSION])
3239
3240 AC_MSG_CHECKING(if GNAT supports generics)
3241 case "$cf_cv_gnat_version" in
3242 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
3243         cf_gnat_generics=yes
3244         ;;
3245 (*)
3246         cf_gnat_generics=no
3247         ;;
3248 esac
3249 AC_MSG_RESULT($cf_gnat_generics)
3250
3251 if test "$cf_gnat_generics" = yes
3252 then
3253         cf_compile_generics=generics
3254         cf_generic_objects="\${GENOBJS}"
3255 else
3256         cf_compile_generics=
3257         cf_generic_objects=
3258 fi
3259
3260 AC_SUBST(cf_compile_generics)
3261 AC_SUBST(cf_generic_objects)
3262 ])dnl
3263 dnl ---------------------------------------------------------------------------
3264 dnl CF_GNAT_PROJECTS version: 13 updated: 2021/01/02 17:09:14
3265 dnl ----------------
3266 dnl GNAT projects are configured with ".gpr" project files.
3267 dnl GNAT libraries are a further development, using the project feature.
3268 AC_DEFUN([CF_GNAT_PROJECTS],
3269 [
3270 AC_REQUIRE([CF_GNAT_VERSION])
3271 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
3272
3273 cf_gnat_libraries=no
3274 cf_gnat_projects=no
3275
3276 if test "$enable_gnat_projects" != no ; then
3277 AC_MSG_CHECKING(if GNAT supports project files)
3278 case "$cf_cv_gnat_version" in
3279 (3.[[0-9]]*)
3280         ;;
3281 (*)
3282         case "$cf_cv_system_name" in
3283         (cygwin*|msys*)
3284                 ;;
3285         (*)
3286                 rm -rf ./conftest* ./*~conftest*
3287                 if mkdir conftest.src conftest.bin conftest.lib
3288                 then
3289                         cd conftest.src
3290                         rm -rf ./conftest* ./*~conftest*
3291                         cat >>library.gpr <<CF_EOF
3292 project Library is
3293   Kind := External ("LIB_KIND");
3294   for Library_Name use "ConfTest";
3295   for Object_Dir use ".";
3296   for Library_ALI_Dir use External("LIBRARY_DIR");
3297   for Library_Version use External ("SONAME");
3298   for Library_Kind use Kind;
3299   for Library_Dir use External("BUILD_DIR");
3300   Source_Dir := External ("SOURCE_DIR");
3301   for Source_Dirs use (Source_Dir);
3302 end Library;
3303 CF_EOF
3304                         cat >>confpackage.ads <<CF_EOF
3305 package ConfPackage is
3306    procedure conftest;
3307 end ConfPackage;
3308 CF_EOF
3309                         cat >>confpackage.adb <<CF_EOF
3310 with Text_IO;
3311 package body ConfPackage is
3312    procedure conftest is
3313    begin
3314       Text_IO.Put ("Hello World");
3315       Text_IO.New_Line;
3316    end conftest;
3317 end ConfPackage;
3318 CF_EOF
3319                         if ( "$cf_ada_make" $ADAFLAGS \
3320                                         -Plibrary.gpr \
3321                                         -XBUILD_DIR="`cd ../conftest.bin;pwd`" \
3322                                         -XLIBRARY_DIR="`cd ../conftest.lib;pwd`" \
3323                                         -XSOURCE_DIR="`pwd`" \
3324                                         -XSONAME=libConfTest.so.1 \
3325                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
3326                                 cf_gnat_projects=yes
3327                         fi
3328                         cd ..
3329                 fi
3330                 if test -f conftest.lib/confpackage.ali
3331                 then
3332                         cf_gnat_libraries=yes
3333                 fi
3334                 rm -rf ./conftest* ./*~conftest*
3335                 ;;
3336         esac
3337         ;;
3338 esac
3339 AC_MSG_RESULT($cf_gnat_projects)
3340 fi # enable_gnat_projects
3341
3342 if test "$cf_gnat_projects" = yes
3343 then
3344         AC_MSG_CHECKING(if GNAT supports libraries)
3345         AC_MSG_RESULT($cf_gnat_libraries)
3346 fi
3347
3348 USE_OLD_MAKERULES=""
3349 USE_GNAT_PROJECTS="#"
3350 USE_GNAT_MAKE_GPR="#"
3351 USE_GNAT_GPRBUILD="#"
3352
3353 if test "$cf_gnat_projects" = yes
3354 then
3355         USE_OLD_MAKERULES="#"
3356         USE_GNAT_PROJECTS=""
3357         if test "$cf_cv_VERSION_GPRBUILD" != no
3358         then
3359                 USE_GNAT_GPRBUILD=""
3360         elif test "$cf_cv_VERSION_GNATMAKE" != no
3361         then
3362                 USE_GNAT_MAKE_GPR=""
3363         else
3364                 AC_MSG_WARN(use old makefile rules since tools are missing)
3365         fi
3366 fi
3367
3368 if test "$cf_gnat_libraries" = yes
3369 then
3370         USE_GNAT_LIBRARIES=""
3371 else
3372         USE_GNAT_LIBRARIES="#"
3373 fi
3374
3375 AC_SUBST(USE_OLD_MAKERULES)
3376 AC_SUBST(USE_GNAT_PROJECTS)
3377 AC_SUBST(USE_GNAT_LIBRARIES)
3378 AC_SUBST(USE_GNAT_MAKE_GPR)
3379 AC_SUBST(USE_GNAT_GPRBUILD)
3380 ])dnl
3381 dnl ---------------------------------------------------------------------------
3382 dnl CF_GNAT_SIGINT version: 2 updated: 2021/01/01 13:31:04
3383 dnl --------------
3384 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
3385 dnl is noted that gnat may compile a tasking unit even for configurations which
3386 dnl fail at runtime.
3387 AC_DEFUN([CF_GNAT_SIGINT],[
3388 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
3389 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
3390
3391 package ConfTest is
3392
3393    pragma Warnings (Off);  --  the next pragma exists since 3.11p
3394    pragma Unreserve_All_Interrupts;
3395    pragma Warnings (On);
3396
3397    protected Process is
3398       procedure Stop;
3399       function Continue return Boolean;
3400       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
3401    private
3402       Done : Boolean := False;
3403    end Process;
3404
3405 end ConfTest;],
3406 [package body ConfTest is
3407    protected body Process is
3408       procedure Stop is
3409       begin
3410          Done := True;
3411       end Stop;
3412       function Continue return Boolean is
3413       begin
3414          return not Done;
3415       end Continue;
3416    end Process;
3417 end ConfTest;],
3418         [cf_cv_gnat_sigint=yes],
3419         [cf_cv_gnat_sigint=no])])
3420
3421 if test "$cf_cv_gnat_sigint" = yes ; then
3422         USE_GNAT_SIGINT=""
3423 else
3424         USE_GNAT_SIGINT="#"
3425 fi
3426 AC_SUBST(USE_GNAT_SIGINT)
3427 ])dnl
3428 dnl ---------------------------------------------------------------------------
3429 dnl CF_GNAT_TRY_LINK version: 4 updated: 2021/01/01 13:31:04
3430 dnl ----------------
3431 dnl Verify that a test program compiles/links with GNAT.
3432 dnl $cf_ada_make is set to the program that compiles/links
3433 dnl $ADAFLAGS may be set to the GNAT flags.
3434 dnl
3435 dnl $1 is the text of the spec
3436 dnl $2 is the text of the body
3437 dnl $3 is the shell command to execute if successful
3438 dnl $4 is the shell command to execute if not successful
3439 AC_DEFUN([CF_GNAT_TRY_LINK],
3440 [
3441 rm -rf ./conftest* ./*~conftest*
3442 cat >>conftest.ads <<CF_EOF
3443 $1
3444 CF_EOF
3445 cat >>conftest.adb <<CF_EOF
3446 $2
3447 CF_EOF
3448 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3449 ifelse($3,,      :,[      $3])
3450 ifelse($4,,,[else
3451    $4])
3452 fi
3453 rm -rf ./conftest* ./*~conftest*
3454 ])dnl
3455 dnl ---------------------------------------------------------------------------
3456 dnl CF_GNAT_TRY_RUN version: 6 updated: 2021/01/01 13:31:04
3457 dnl ---------------
3458 dnl Verify that a test program compiles and runs with GNAT
3459 dnl $cf_ada_make is set to the program that compiles/links
3460 dnl $ADAFLAGS may be set to the GNAT flags.
3461 dnl
3462 dnl $1 is the text of the spec
3463 dnl $2 is the text of the body
3464 dnl $3 is the shell command to execute if successful
3465 dnl $4 is the shell command to execute if not successful
3466 AC_DEFUN([CF_GNAT_TRY_RUN],
3467 [
3468 rm -rf ./conftest* ./*~conftest*
3469 cat >>conftest.ads <<CF_EOF
3470 $1
3471 CF_EOF
3472 cat >>conftest.adb <<CF_EOF
3473 $2
3474 CF_EOF
3475 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3476    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
3477 ifelse($3,,      :,[      $3])
3478 ifelse($4,,,[   else
3479       $4])
3480    fi
3481 ifelse($4,,,[else
3482    $4])
3483 fi
3484 rm -rf ./conftest* ./*~conftest*
3485 ])dnl
3486 dnl ---------------------------------------------------------------------------
3487 dnl CF_GNAT_VERSION version: 22 updated: 2019/12/31 08:53:54
3488 dnl ---------------
3489 dnl $1 = cache variable to update
3490 dnl $2 = program name
3491 dnl Verify version of GNAT or related tool
3492 AC_DEFUN([CF_GNAT_VERSION],
3493 [
3494 AC_CACHE_CHECK(for ifelse($2,,gnat,$2) version, cf_cv_gnat_version,[
3495 cf_cv_gnat_version=`ifelse($2,,${cf_ada_make:-gnatmake},$2) --version 2>&1 | \
3496         grep '[[0-9]].[[0-9]][[0-9]]*' |\
3497         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
3498 ])
3499 test -z "$cf_cv_gnat_version" && cf_cv_gnat_version=no
3500 ifelse($1,,,[eval $1=$cf_cv_gnat_version; unset cf_cv_gnat_version])
3501 ])dnl
3502 dnl ---------------------------------------------------------------------------
3503 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
3504 dnl -------------
3505 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
3506 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
3507 dnl (or misfeature) of glibc2, which breaks portability of many applications,
3508 dnl since it is interwoven with GNU extensions.
3509 dnl
3510 dnl Well, yes we could work around it...
3511 dnl
3512 dnl Parameters:
3513 dnl     $1 is the nominal value for _XOPEN_SOURCE
3514 AC_DEFUN([CF_GNU_SOURCE],
3515 [
3516 cf_gnu_xopen_source=ifelse($1,,500,$1)
3517
3518 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
3519 AC_TRY_COMPILE([#include <sys/types.h>],[
3520         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
3521                 return 0;
3522         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
3523                 return 0;
3524         #else
3525         #       error not GNU C library
3526         #endif],
3527         [cf_cv_gnu_library=yes],
3528         [cf_cv_gnu_library=no])
3529 ])
3530
3531 if test x$cf_cv_gnu_library = xyes; then
3532
3533         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
3534         # was changed to help a little.  newlib incorporated the change about 4
3535         # years later.
3536         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
3537                 cf_save="$CPPFLAGS"
3538                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3539                 AC_TRY_COMPILE([#include <sys/types.h>],[
3540                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
3541                                 return 0;
3542                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
3543                                 return 0;
3544                         #else
3545                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
3546                         #endif],
3547                         [cf_cv_gnu_library_219=yes],
3548                         [cf_cv_gnu_library_219=no])
3549                 CPPFLAGS="$cf_save"
3550         ])
3551
3552         if test "x$cf_cv_gnu_library_219" = xyes; then
3553                 cf_save="$CPPFLAGS"
3554                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
3555                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
3556                         AC_TRY_COMPILE([
3557                                 #include <limits.h>
3558                                 #include <sys/types.h>
3559                                 ],[
3560                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
3561                                         return 0;
3562                                 #else
3563                                 #       error GNU C library is too old
3564                                 #endif],
3565                                 [cf_cv_gnu_dftsrc_219=yes],
3566                                 [cf_cv_gnu_dftsrc_219=no])
3567                         ])
3568                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
3569         else
3570                 cf_cv_gnu_dftsrc_219=maybe
3571         fi
3572
3573         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
3574
3575                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
3576                 AC_TRY_COMPILE([#include <sys/types.h>],[
3577                         #ifndef _XOPEN_SOURCE
3578                         #error  expected _XOPEN_SOURCE to be defined
3579                         #endif],
3580                         [cf_cv_gnu_source=no],
3581                         [cf_save="$CPPFLAGS"
3582                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
3583                          AC_TRY_COMPILE([#include <sys/types.h>],[
3584                                 #ifdef _XOPEN_SOURCE
3585                                 #error  expected _XOPEN_SOURCE to be undefined
3586                                 #endif],
3587                                 [cf_cv_gnu_source=no],
3588                                 [cf_cv_gnu_source=yes])
3589                         CPPFLAGS="$cf_save"
3590                         ])
3591                 ])
3592
3593                 if test "$cf_cv_gnu_source" = yes
3594                 then
3595                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
3596                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
3597                         AC_TRY_COMPILE([#include <sys/types.h>],[
3598                                 #ifdef _DEFAULT_SOURCE
3599                                 #error  expected _DEFAULT_SOURCE to be undefined
3600                                 #endif],
3601                                 [cf_cv_default_source=no],
3602                                 [cf_cv_default_source=yes])
3603                         ])
3604                         if test "$cf_cv_default_source" = yes
3605                         then
3606                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3607                         fi
3608                 fi
3609         fi
3610
3611 fi
3612 ])dnl
3613 dnl ---------------------------------------------------------------------------
3614 dnl CF_GPP_LIBRARY version: 13 updated: 2021/01/01 13:31:04
3615 dnl --------------
3616 dnl If we're trying to use g++, test if libg++ is installed (a rather common
3617 dnl problem :-).  If we have the compiler but no library, we'll be able to
3618 dnl configure, but won't be able to build the c++ demo program.
3619 AC_DEFUN([CF_GPP_LIBRARY],
3620 [
3621 cf_cxx_library=unknown
3622 case "$cf_cv_system_name" in
3623 (os2*)
3624         cf_gpp_libname=gpp
3625         ;;
3626 (*)
3627         cf_gpp_libname=g++
3628         ;;
3629 esac
3630 if test "$GXX" = yes; then
3631         AC_MSG_CHECKING([for lib$cf_gpp_libname])
3632         cf_save="$LIBS"
3633         CF_ADD_LIB($cf_gpp_libname)
3634         AC_TRY_LINK([
3635 #include <$cf_gpp_libname/builtin.h>
3636         ],
3637         [two_arg_error_handler_t foo2 = lib_error_handler],
3638         [cf_cxx_library=yes
3639          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3640          if test "$cf_gpp_libname" = cpp ; then
3641             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
3642          else
3643             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
3644          fi],
3645         [AC_TRY_LINK([
3646 #include <builtin.h>
3647         ],
3648         [two_arg_error_handler_t foo2 = lib_error_handler],
3649         [cf_cxx_library=yes
3650          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3651          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
3652         [cf_cxx_library=no])])
3653         LIBS="$cf_save"
3654         AC_MSG_RESULT($cf_cxx_library)
3655 fi
3656 ])dnl
3657 dnl ---------------------------------------------------------------------------
3658 dnl CF_GXX_VERSION version: 9 updated: 2023/03/05 14:30:13
3659 dnl --------------
3660 dnl Check for version of g++
3661 AC_DEFUN([CF_GXX_VERSION],[
3662 AC_REQUIRE([AC_PROG_CPP])
3663 GXX_VERSION=none
3664 if test "$GXX" = yes; then
3665         AC_MSG_CHECKING(version of ${CXX:-g++})
3666         GXX_VERSION="`${CXX:-g++} --version 2>/dev/null | sed -e '2,$d' -e 's/^[[^(]]*([[^)]][[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
3667         if test -z "$GXX_VERSION"
3668         then
3669                 GXX_VERSION=unknown
3670                 GXX=no
3671         fi
3672         AC_MSG_RESULT($GXX_VERSION)
3673 fi
3674 ])dnl
3675 dnl ---------------------------------------------------------------------------
3676 dnl CF_GXX_WARNINGS version: 11 updated: 2021/01/08 16:50:55
3677 dnl ---------------
3678 dnl Check if the compiler supports useful warning options.
3679 dnl
3680 dnl Most of gcc's options apply to g++, except:
3681 dnl     -Wbad-function-cast
3682 dnl     -Wmissing-declarations
3683 dnl     -Wnested-externs
3684 dnl
3685 dnl Omit a few (for now):
3686 dnl     -Winline
3687 dnl
3688 dnl Parameter:
3689 dnl     $1 is an optional list of g++ warning flags that a particular
3690 dnl             application might want to use, e.g., "no-unused" for
3691 dnl             -Wno-unused
3692 dnl Special:
3693 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
3694 dnl
3695 AC_DEFUN([CF_GXX_WARNINGS],
3696 [
3697
3698 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
3699 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
3700
3701 AC_REQUIRE([CF_GXX_VERSION])
3702
3703 AC_LANG_SAVE
3704 AC_LANG_CPLUSPLUS
3705
3706 cat > conftest.$ac_ext <<EOF
3707 #line __oline__ "configure"
3708 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
3709 EOF
3710
3711 if test "$INTEL_CPLUSPLUS" = yes
3712 then
3713 # The "-wdXXX" options suppress warnings:
3714 # remark #1419: external declaration in primary source file
3715 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3716 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3717 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
3718 # remark #193: zero used for undefined preprocessing identifier
3719 # remark #593: variable "curs_sb_left_arrow" was set but never used
3720 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
3721 # remark #869: parameter "tw" was never referenced
3722 # remark #981: operands are evaluated in unspecified order
3723 # warning #269: invalid format string conversion
3724
3725         AC_CHECKING([for $CC warning options])
3726         cf_save_CXXFLAGS="$CXXFLAGS"
3727         EXTRA_CXXFLAGS="-Wall"
3728         for cf_opt in \
3729                 wd1419 \
3730                 wd1682 \
3731                 wd1683 \
3732                 wd1684 \
3733                 wd193 \
3734                 wd279 \
3735                 wd593 \
3736                 wd810 \
3737                 wd869 \
3738                 wd981
3739         do
3740                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
3741                 if AC_TRY_EVAL(ac_compile); then
3742                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3743                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3744                 fi
3745         done
3746         CXXFLAGS="$cf_save_CXXFLAGS"
3747
3748 elif test "$GXX" = yes
3749 then
3750         AC_CHECKING([for $CXX warning options])
3751         cf_save_CXXFLAGS="$CXXFLAGS"
3752         EXTRA_CXXFLAGS="-W -Wall"
3753         cf_gxx_extra_warnings=""
3754         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
3755         case "$GXX_VERSION" in
3756         ([[1-2]].*)
3757                 ;;
3758         (*)
3759                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
3760                 ;;
3761         esac
3762         for cf_opt in \
3763                 Wabi \
3764                 fabi-version=0 \
3765                 Wextra \
3766                 Wignored-qualifiers \
3767                 Wlogical-op \
3768                 Woverloaded-virtual \
3769                 Wsign-promo \
3770                 Wsynth \
3771                 Wold-style-cast \
3772                 Wcast-align \
3773                 Wcast-qual \
3774                 Wpointer-arith \
3775                 Wshadow \
3776                 Wundef $cf_gxx_extra_warnings $1
3777         do
3778                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
3779                 if AC_TRY_EVAL(ac_compile); then
3780                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3781                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3782                 else
3783                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
3784                 fi
3785         done
3786         CXXFLAGS="$cf_save_CXXFLAGS"
3787 fi
3788
3789 rm -rf ./conftest*
3790 AC_LANG_RESTORE
3791 AC_SUBST(EXTRA_CXXFLAGS)
3792 ])dnl
3793 dnl ---------------------------------------------------------------------------
3794 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
3795 dnl ------------
3796 dnl Look for an instance of the Berkeley hashed database.
3797 dnl
3798 dnl $1 = optional parameter, to specify install-prefix for the database.
3799 AC_DEFUN([CF_HASHED_DB],
3800 [
3801 ifelse([$1],,,[
3802 case $1 in
3803 (yes|*able*)
3804         ;;
3805 (*)
3806         if test -d "$1" ; then
3807                 CF_ADD_INCDIR($1/include)
3808                 CF_ADD_LIBDIR($1/lib)
3809         else
3810                 case "$1" in
3811                 (./*|../*|/*)
3812                         AC_MSG_WARN(no such directory $1)
3813                         ;;
3814                 (*)
3815                         CF_FIND_SUB_INCDIR($1)
3816                         CF_FIND_SUB_LIBDIR($1)
3817                         ;;
3818                 esac
3819         fi
3820 esac
3821 ])
3822 AC_CHECK_HEADER(db.h,[
3823 CF_HASHED_DB_VERSION
3824 if test "$cf_cv_hashed_db_version" = unknown ; then
3825         AC_MSG_ERROR(Cannot determine version of db)
3826 else
3827         CF_HASHED_DB_LIBS
3828         if test "$cf_cv_hashed_db_libs" = unknown ; then
3829                 AC_MSG_ERROR(Cannot determine library for db)
3830         elif test "$cf_cv_hashed_db_libs" != default ; then
3831                 CF_ADD_LIB($cf_cv_hashed_db_libs)
3832         fi
3833 fi
3834 ],[
3835         AC_MSG_ERROR(Cannot find db.h)
3836 ])
3837 ])dnl
3838 dnl ---------------------------------------------------------------------------
3839 dnl CF_HASHED_DB_LIBS version: 10 updated: 2021/01/02 17:09:14
3840 dnl -----------------
3841 dnl Given that we have the header and version for hashed database, find the
3842 dnl library information.
3843 AC_DEFUN([CF_HASHED_DB_LIBS],
3844 [
3845 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
3846 cf_cv_hashed_db_libs=unknown
3847 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
3848 do
3849         cf_save_libs="$LIBS"
3850         if test -n "$cf_db_libs"; then
3851                 CF_ADD_LIB($cf_db_libs)
3852         fi
3853         CF_MSG_LOG(checking for library $cf_db_libs)
3854         AC_TRY_LINK([
3855 $ac_includes_default
3856 #include <db.h>
3857 ],[
3858         char *path = "/tmp/foo";
3859 #ifdef DB_VERSION_MAJOR
3860 #if DB_VERSION_MAJOR >= 4
3861         DB *result = 0;
3862         db_create(&result, NULL, 0);
3863         result->open(result,
3864                 NULL,
3865                 path,
3866                 path,
3867                 DB_HASH,
3868                 DB_CREATE,
3869                 0644);
3870 #elif DB_VERSION_MAJOR >= 3
3871         DB *result = 0;
3872         db_create(&result, NULL, 0);
3873         result->open(result,
3874                 path,
3875                 path,
3876                 DB_HASH,
3877                 DB_CREATE,
3878                 0644);
3879 #elif DB_VERSION_MAJOR >= 2
3880         DB *result = 0;
3881         db_open(path,
3882                 DB_HASH,
3883                 DB_CREATE,
3884                 0644,
3885                 (DB_ENV *) 0,
3886                 (DB_INFO *) 0,
3887                 &result);
3888 #endif /* DB_VERSION_MAJOR */
3889 #else
3890         DB *result = dbopen(path,
3891                      2,
3892                      0644,
3893                      DB_HASH,
3894                      0);
3895 #endif
3896         ${cf_cv_main_return:-return}(result != 0)
3897 ],[
3898         if test -n "$cf_db_libs" ; then
3899                 cf_cv_hashed_db_libs=$cf_db_libs
3900         else
3901                 cf_cv_hashed_db_libs=default
3902         fi
3903         LIBS="$cf_save_libs"
3904         break
3905 ])
3906         LIBS="$cf_save_libs"
3907 done
3908 ])
3909 ])dnl
3910 dnl ---------------------------------------------------------------------------
3911 dnl CF_HASHED_DB_VERSION version: 5 updated: 2023/02/18 17:41:25
3912 dnl --------------------
3913 dnl Given that we have the header file for hashed database, find the version
3914 dnl information.
3915 AC_DEFUN([CF_HASHED_DB_VERSION],
3916 [
3917 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3918 cf_cv_hashed_db_version=unknown
3919
3920 for cf_db_version in 1 2 3 4 5 6
3921 do
3922         CF_MSG_LOG(checking for db version $cf_db_version)
3923         AC_TRY_COMPILE([
3924 $ac_includes_default
3925 #include <db.h>
3926
3927 #ifdef DB_VERSION_MAJOR
3928         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3929 #if $cf_db_version == DB_VERSION_MAJOR
3930         /* ok */
3931 #else
3932         #error $cf_db_version is not DB_VERSION_MAJOR
3933 #endif
3934 #else
3935 #if $cf_db_version == 1
3936         /* ok: assuming this is DB 1.8.5 */
3937 #else
3938         #error $cf_db_version is not 1
3939 #endif
3940 #endif
3941 ],[DBT *foo = 0],[
3942         cf_cv_hashed_db_version=$cf_db_version
3943         break
3944         ])
3945 done
3946 ])
3947 ])dnl
3948 dnl ---------------------------------------------------------------------------
3949 dnl CF_HEADER_PATH version: 15 updated: 2021/01/01 13:31:04
3950 dnl --------------
3951 dnl Construct a search-list of directories for a nonstandard header-file
3952 dnl
3953 dnl Parameters
3954 dnl     $1 = the variable to return as result
3955 dnl     $2 = the package name
3956 AC_DEFUN([CF_HEADER_PATH],
3957 [
3958 $1=
3959
3960 # collect the current set of include-directories from compiler flags
3961 cf_header_path_list=""
3962 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3963         for cf_header_path in $CPPFLAGS $CFLAGS
3964         do
3965                 case "$cf_header_path" in
3966                 (-I*)
3967                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3968                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3969                         cf_header_path_list="$cf_header_path_list [$]$1"
3970                         ;;
3971                 esac
3972         done
3973 fi
3974
3975 # add the variations for the package we are looking for
3976 CF_SUBDIR_PATH($1,$2,include)
3977
3978 test "$includedir" != NONE && \
3979 test "$includedir" != "/usr/include" && \
3980 test -d "$includedir" && {
3981         test -d "$includedir" &&    $1="[$]$1 $includedir"
3982         test -d "$includedir/$2" && $1="[$]$1 $includedir/$2"
3983 }
3984
3985 test "$oldincludedir" != NONE && \
3986 test "$oldincludedir" != "/usr/include" && \
3987 test -d "$oldincludedir" && {
3988         test -d "$oldincludedir"    && $1="[$]$1 $oldincludedir"
3989         test -d "$oldincludedir/$2" && $1="[$]$1 $oldincludedir/$2"
3990 }
3991
3992 $1="[$]$1 $cf_header_path_list"
3993 ])dnl
3994 dnl ---------------------------------------------------------------------------
3995 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
3996 dnl ---------------
3997 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3998 AC_DEFUN([CF_HELP_MESSAGE],
3999 [CF_ACVERSION_CHECK(2.53,[],[
4000 AC_DIVERT_HELP($1)])dnl
4001 ])dnl
4002 dnl ---------------------------------------------------------------------------
4003 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
4004 dnl ---------------
4005 dnl Construct the list of include-options according to whether we're building
4006 dnl in the source directory or using '--srcdir=DIR' option.
4007 AC_DEFUN([CF_INCLUDE_DIRS],
4008 [
4009 if test "$srcdir" != "."; then
4010         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
4011 fi
4012 CPPFLAGS="-I../include $CPPFLAGS"
4013 if test "$srcdir" != "."; then
4014         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
4015 fi
4016 CPPFLAGS="-I. $CPPFLAGS"
4017 AC_SUBST(CPPFLAGS)
4018 ])dnl
4019 dnl ---------------------------------------------------------------------------
4020 dnl CF_INSTALL_OPTS version: 3 updated: 2023/06/03 15:17:30
4021 dnl ---------------
4022 dnl prompt for/fill-in useful install-program options
4023 AC_DEFUN([CF_INSTALL_OPTS],
4024 [
4025 CF_INSTALL_OPT_S
4026 CF_INSTALL_OPT_P
4027 CF_INSTALL_OPT_O
4028 CF_INSTALL_OPT_STRIP_PROG
4029 ])dnl
4030 dnl ---------------------------------------------------------------------------
4031 dnl CF_INSTALL_OPT_O version: 3 updated: 2020/12/31 20:19:42
4032 dnl ----------------
4033 dnl Almost all "install" programs default to the current user's ownership.
4034 dnl Almost - MINIX is an exception.
4035 AC_DEFUN([CF_INSTALL_OPT_O],
4036 [
4037 AC_MSG_CHECKING(if install needs to be told about ownership)
4038 case `$ac_config_guess` in
4039 (*minix)
4040         with_install_o=yes
4041         ;;
4042 (*)
4043         with_install_o=no
4044         ;;
4045 esac
4046
4047 AC_MSG_RESULT($with_install_o)
4048 if test "x$with_install_o" = xyes
4049 then
4050         INSTALL_OPT_O="`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`"
4051 else
4052         INSTALL_OPT_O=
4053 fi
4054
4055 AC_SUBST(INSTALL_OPT_O)
4056 ])dnl
4057 dnl ---------------------------------------------------------------------------
4058 dnl CF_INSTALL_OPT_P version: 3 updated: 2021/01/01 13:31:04
4059 dnl ----------------
4060 dnl Some install-programs accept a "-p" option to preserve file modification
4061 dnl timestamps.  That can be useful as an install option, as well as a way to
4062 dnl avoid the need for ranlib after copying a static archive.
4063 AC_DEFUN([CF_INSTALL_OPT_P],
4064 [
4065 : "${INSTALL:=install}"
4066 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
4067         rm -rf ./conftest*
4068         date >conftest.in
4069         mkdir conftest.out
4070         sleep 3
4071         if $INSTALL -p conftest.in conftest.out 2>/dev/null
4072         then
4073                 if test -f conftest.out/conftest.in
4074                 then
4075                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
4076                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
4077                         if test -s conftest.err
4078                         then
4079                                 cf_cv_install_p=no
4080                         else
4081                                 cf_cv_install_p=yes
4082                         fi
4083                 else
4084                         cf_cv_install_p=no
4085                 fi
4086         else
4087                 cf_cv_install_p=no
4088         fi
4089         rm -rf ./conftest*
4090 ])
4091 ])dnl
4092 dnl ---------------------------------------------------------------------------
4093 dnl CF_INSTALL_OPT_S version: 3 updated: 2021/01/05 19:23:48
4094 dnl ----------------
4095 dnl By default, we should strip executables which are installed, but leave the
4096 dnl ability to suppress that for unit-testing.
4097 AC_DEFUN([CF_INSTALL_OPT_S],
4098 [
4099 AC_MSG_CHECKING(if you want to install stripped executables)
4100 CF_ARG_DISABLE(stripping,
4101         [  --disable-stripping     do not strip (debug info) installed executables],
4102         [enable_stripping=no],
4103         [enable_stripping=yes])
4104 AC_MSG_RESULT($enable_stripping)
4105
4106 if test "$enable_stripping" = yes
4107 then
4108         INSTALL_OPT_S="-s"
4109 else
4110         INSTALL_OPT_S=
4111 fi
4112 AC_SUBST(INSTALL_OPT_S)
4113 ])dnl
4114 dnl ---------------------------------------------------------------------------
4115 dnl CF_INSTALL_OPT_STRIP_PROG version: 1 updated: 2023/06/03 15:17:30
4116 dnl -------------------------
4117 dnl Provide an option for overriding the strip program used in install "-s"
4118 dnl
4119 dnl coreutils install provides a --strip-program option
4120 dnl FreeBSD uses STRIPBIN environment variable, while NetBSD and OpenBSD use
4121 dnl STRIP environment variable.  Other versions of install do not support this.
4122 AC_DEFUN([CF_INSTALL_OPT_STRIP_PROG],
4123 [
4124 AC_REQUIRE([CF_INSTALL_OPT_S])
4125 if test -n "$INSTALL_OPT_S"
4126 then
4127         AC_MSG_CHECKING(if you want to specify strip-program)
4128         AC_ARG_WITH(strip-program,
4129                 [  --with-strip-program=XX specify program to use when stripping in install],
4130                 [with_strip_program=$withval],
4131                 [with_strip_program=no])
4132         AC_MSG_RESULT($with_strip_program)
4133         if test "$with_strip_program" != no
4134         then
4135                 AC_MSG_CHECKING(if strip-program is supported with this installer)
4136                 cf_install_program=`echo "$INSTALL" | sed -e 's%[[ ]]*[[ ]]-.%%'`
4137                 check_install_strip=no
4138                 if test -f "$cf_install_program"
4139                 then
4140                         check_install_version=`"$cf_install_program" --version 2>/dev/null | head -n 1 | grep coreutils`
4141                         if test -n "$check_install_version"
4142                         then
4143                                 check_install_strip="option"
4144                         else
4145                                 for check_strip_variable in STRIPBIN STRIP
4146                                 do
4147                                         if strings "$cf_install_program" | grep "^$check_strip_variable[$]" >/dev/null
4148                                         then
4149                                                 check_install_strip="environ"
4150                                                 break
4151                                         fi
4152                                 done
4153                         fi
4154                 fi
4155                 AC_MSG_RESULT($check_install_strip)
4156                 case "$check_install_strip" in
4157                 (no)
4158                         AC_MSG_WARN($cf_install_program does not support strip program option)
4159                         with_strip_program=no
4160                         ;;
4161                 (environ)
4162                         cat >install.tmp <<-CF_EOF
4163                         #! $SHELL
4164                         STRIPBIN="$with_strip_program" \\
4165                         STRIP="$with_strip_program" \\
4166                         $INSTALL "[$]@"
4167                         CF_EOF
4168                         INSTALL="`pwd`/install.tmp"
4169                         chmod +x "$INSTALL"
4170                         CF_VERBOSE(created $INSTALL)
4171                         ;;
4172                 (option)
4173                         INSTALL_OPT_S="$INSTALL_OPT_S --strip-program=\"$with_strip_program\""
4174                         ;;
4175                 esac
4176         fi
4177 fi
4178 AC_SUBST(INSTALL_OPT_S)
4179 ])dnl
4180 dnl ---------------------------------------------------------------------------
4181 dnl CF_INTEL_COMPILER version: 9 updated: 2023/02/18 17:41:25
4182 dnl -----------------
4183 dnl Check if the given compiler is really the Intel compiler for Linux.  It
4184 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
4185 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
4186 dnl
4187 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
4188 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
4189 dnl the wrappers for gcc and g++ warnings.
4190 dnl
4191 dnl $1 = GCC (default) or GXX
4192 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
4193 dnl $3 = CFLAGS (default) or CXXFLAGS
4194 AC_DEFUN([CF_INTEL_COMPILER],[
4195 AC_REQUIRE([AC_CANONICAL_HOST])
4196 ifelse([$2],,INTEL_COMPILER,[$2])=no
4197
4198 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
4199         case "$host_os" in
4200         (linux*|gnu*)
4201                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
4202                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
4203                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
4204                 AC_TRY_COMPILE([],[
4205 #ifdef __INTEL_COMPILER
4206 #else
4207 #error __INTEL_COMPILER is not defined
4208 #endif
4209 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
4210 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
4211 ],[])
4212                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
4213                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
4214                 ;;
4215         esac
4216 fi
4217 ])dnl
4218 dnl ---------------------------------------------------------------------------
4219 dnl CF_ISASCII version: 5 updated: 2023/12/03 09:21:34
4220 dnl ----------
4221 dnl Check if we have either a function or macro for 'isascii()'.
4222 AC_DEFUN([CF_ISASCII],
4223 [
4224 AC_MSG_CHECKING(for isascii)
4225 AC_CACHE_VAL(cf_cv_have_isascii,[
4226         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' '); (void)x],
4227         [cf_cv_have_isascii=yes],
4228         [cf_cv_have_isascii=no])
4229 ])dnl
4230 AC_MSG_RESULT($cf_cv_have_isascii)
4231 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
4232 ])dnl
4233 dnl ---------------------------------------------------------------------------
4234 dnl CF_LARGEFILE version: 13 updated: 2023/12/03 19:09:59
4235 dnl ------------
4236 dnl Add checks for large file support.
4237 AC_DEFUN([CF_LARGEFILE],[
4238 ifdef([AC_FUNC_FSEEKO],[
4239         AC_SYS_LARGEFILE
4240         if test "$enable_largefile" != no ; then
4241         AC_FUNC_FSEEKO
4242
4243         # Normally we would collect these definitions in the config.h,
4244         # but (like _XOPEN_SOURCE), some environments rely on having these
4245         # defined before any of the system headers are included.  Another
4246         # case comes up with C++, e.g., on AIX the compiler compiles the
4247         # header files by themselves before looking at the body files it is
4248         # told to compile.  For ncurses, those header files do not include
4249         # the config.h
4250         if test "$ac_cv_sys_large_files" != no
4251         then
4252                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
4253         fi
4254         if test "$ac_cv_sys_largefile_source" != no
4255         then
4256                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
4257         fi
4258         if test "$ac_cv_sys_file_offset_bits" != no
4259         then
4260                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
4261         fi
4262
4263         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
4264                 AC_TRY_COMPILE([
4265 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
4266 #include <sys/types.h>
4267 #include <dirent.h>
4268
4269 #ifndef __REDIRECT
4270 /* if transitional largefile support is setup, this is true */
4271 extern struct dirent64 * readdir(DIR *);
4272 #endif
4273                 ],[
4274                 DIR *dp = opendir(".");
4275                 struct dirent64 *x = readdir(dp);
4276                 struct dirent *y = readdir(dp);
4277                 int z = x - y;
4278                 (void)z;
4279                 ],
4280                 [cf_cv_struct_dirent64=yes],
4281                 [cf_cv_struct_dirent64=no])
4282         ])
4283         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
4284         fi
4285 ])
4286 ])
4287 dnl ---------------------------------------------------------------------------
4288 dnl CF_LDFLAGS_STATIC version: 14 updated: 2021/01/02 17:09:14
4289 dnl -----------------
4290 dnl Check for compiler/linker flags used to temporarily force usage of static
4291 dnl libraries.  This depends on the compiler and platform.  Use this to help
4292 dnl ensure that the linker picks up a given library based on its position in
4293 dnl the list of linker options and libraries.
4294 AC_DEFUN([CF_LDFLAGS_STATIC],[
4295
4296 if test "$GCC" = yes ; then
4297         case "$cf_cv_system_name" in
4298         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
4299                 LDFLAGS_STATIC=
4300                 LDFLAGS_SHARED=
4301                 ;;
4302         (*)     # normally, except when broken
4303                 LDFLAGS_STATIC=-static
4304                 LDFLAGS_SHARED=-dynamic
4305                 ;;
4306         esac
4307 else
4308         case "$cf_cv_system_name" in
4309         (aix[[4-7]]*)   # from ld manpage
4310                 LDFLAGS_STATIC=-bstatic
4311                 LDFLAGS_SHARED=-bdynamic
4312                 ;;
4313         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
4314                 # We could also use just "archive" and "shared".
4315                 LDFLAGS_STATIC=-Wl,-a,archive_shared
4316                 LDFLAGS_SHARED=-Wl,-a,shared_archive
4317                 ;;
4318         (irix*)         # from ld manpage IRIX64
4319                 LDFLAGS_STATIC=-Bstatic
4320                 LDFLAGS_SHARED=-Bdynamic
4321                 ;;
4322         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
4323                 # alternative "-oldstyle_liblookup" (not in cc manpage)
4324                 LDFLAGS_STATIC=-noso
4325                 LDFLAGS_SHARED=-so_archive
4326                 ;;
4327         (solaris2*)
4328                 LDFLAGS_STATIC=-Bstatic
4329                 LDFLAGS_SHARED=-Bdynamic
4330                 ;;
4331         esac
4332 fi
4333
4334 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
4335 then
4336         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
4337
4338         rm -f libconftest.a
4339         cat >conftest.$ac_ext <<EOF
4340 #line __oline__ "configure"
4341 #include <stdio.h>
4342 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
4343 EOF
4344         if AC_TRY_EVAL(ac_compile) ; then
4345                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
4346                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
4347         fi
4348         rm -f conftest.*
4349
4350         cf_save_LIBS="$LIBS"
4351
4352         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
4353         AC_TRY_LINK([
4354 #line __oline__ "configure"
4355 #include <stdio.h>
4356 int cf_ldflags_static(FILE *fp);
4357 ],[
4358         return cf_ldflags_static(stdin);
4359 ],[
4360         # some linkers simply ignore the -dynamic
4361         case x`file "conftest$ac_exeext" 2>/dev/null` in
4362         (*static*)
4363                 cf_ldflags_static=no
4364                 ;;
4365         (*)
4366                 cf_ldflags_static=yes
4367                 ;;
4368         esac
4369 ],[cf_ldflags_static=no])
4370
4371         rm -f libconftest.*
4372         LIBS="$cf_save_LIBS"
4373
4374         AC_MSG_RESULT($cf_ldflags_static)
4375
4376         if test "$cf_ldflags_static" != yes
4377         then
4378                 LDFLAGS_STATIC=
4379                 LDFLAGS_SHARED=
4380         fi
4381 else
4382         LDFLAGS_STATIC=
4383         LDFLAGS_SHARED=
4384 fi
4385
4386 AC_SUBST(LDFLAGS_STATIC)
4387 AC_SUBST(LDFLAGS_SHARED)
4388 ])
4389 dnl ---------------------------------------------------------------------------
4390 dnl CF_LD_RPATH_OPT version: 9 updated: 2021/01/01 13:31:04
4391 dnl ---------------
4392 dnl For the given system and compiler, find the compiler flags to pass to the
4393 dnl loader to use the "rpath" feature.
4394 AC_DEFUN([CF_LD_RPATH_OPT],
4395 [
4396 AC_REQUIRE([CF_CHECK_CACHE])
4397
4398 LD_RPATH_OPT=
4399 if test "x$cf_cv_enable_rpath" != xno
4400 then
4401         AC_MSG_CHECKING(for an rpath option)
4402         case "$cf_cv_system_name" in
4403         (irix*)
4404                 if test "$GCC" = yes; then
4405                         LD_RPATH_OPT="-Wl,-rpath,"
4406                 else
4407                         LD_RPATH_OPT="-rpath "
4408                 fi
4409                 ;;
4410         (linux*|gnu*|k*bsd*-gnu|freebsd*)
4411                 LD_RPATH_OPT="-Wl,-rpath,"
4412                 ;;
4413         (openbsd[[2-9]].*|mirbsd*)
4414                 LD_RPATH_OPT="-Wl,-rpath,"
4415                 ;;
4416         (dragonfly*)
4417                 LD_RPATH_OPT="-rpath "
4418                 ;;
4419         (netbsd*)
4420                 LD_RPATH_OPT="-Wl,-rpath,"
4421                 ;;
4422         (osf*|mls+*)
4423                 LD_RPATH_OPT="-rpath "
4424                 ;;
4425         (solaris2*)
4426                 LD_RPATH_OPT="-R"
4427                 ;;
4428         (*)
4429                 ;;
4430         esac
4431         AC_MSG_RESULT($LD_RPATH_OPT)
4432
4433         case "x$LD_RPATH_OPT" in
4434         (x-R*)
4435                 AC_MSG_CHECKING(if we need a space after rpath option)
4436                 cf_save_LIBS="$LIBS"
4437                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
4438                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
4439                 LIBS="$cf_save_LIBS"
4440                 AC_MSG_RESULT($cf_rpath_space)
4441                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
4442                 ;;
4443         esac
4444 fi
4445 ])dnl
4446 dnl ---------------------------------------------------------------------------
4447 dnl CF_LD_SEARCHPATH version: 4 updated: 2022/08/27 15:43:08
4448 dnl ----------------
4449 dnl Try to obtain the linker's search-path, for use in scripts.
4450 dnl
4451 dnl Ignore LD_LIBRARY_PATH, etc.
4452 AC_DEFUN([CF_LD_SEARCHPATH],[
4453 AC_CACHE_CHECK(for linker search path,cf_cv_ld_searchpath,[
4454
4455 if test "$cross_compiling" != yes ; then
4456
4457 # GNU binutils' ld does not involve permissions which may stop ldconfig.
4458 cf_pathlist=`${LD:-ld} --verbose 2>/dev/null | grep SEARCH_DIR | sed -e 's,SEARCH_DIR[[("=]][[("=]]*,,g' -e 's/"[[)]];//gp' | sort -u`
4459
4460 # The -NX options tell newer versions of Linux ldconfig to not attempt to
4461 # update the cache, which makes it run faster.
4462 test -z "$cf_pathlist" && \
4463         cf_pathlist=`(ldconfig -NX -v) 2>/dev/null | sed -e '/^[[       ]]/d' -e 's/:$//' | sort -u`
4464
4465 test -z "$cf_pathlist" &&
4466         cf_pathlist=`(ldconfig -v) 2>/dev/null | sed -n -e '/^[[        ]]/d' -e 's/:$//p' | sort -u`
4467
4468 # This works with OpenBSD 6.5, which lists only filenames
4469 test -z "$cf_pathlist" &&
4470         cf_pathlist=`(ldconfig -v) 2>/dev/null | sed -n -e 's,^Adding \(.*\)/.*[$],\1,p' | sort -u`
4471
4472 if test -z "$cf_pathlist"
4473 then
4474         # dyld default path with MacOS
4475         if test -f /usr/bin/otool && test "x`uname -s`" = xDarwin
4476         then
4477                 # do this to bypass check
4478                 cf_cv_ld_searchpath='$HOME/lib'
4479                 cf_pathlist="/usr/local/lib /lib /usr/lib"
4480         fi
4481 fi
4482
4483 if test -z "$cf_pathlist"
4484 then
4485         # Solaris is "SunOS"
4486         if test -f /usr/bin/isainfo && test "x`uname -s`" = xSunOS
4487         then
4488                 case x`(isainfo -b)` in
4489                 (x64)
4490                         cf_pathlist="$cf_pathlist /lib/64 /usr/lib/64"
4491                         ;;
4492                 (x32)
4493                         test -d /usr/ccs/lib && cf_pathlist="$cf_pathlist /usr/ccs/lib"
4494                         cf_pathlist="$cf_pathlist /lib /usr/lib"
4495                         ;;
4496                 (*)
4497                         AC_MSG_WARN(problem with Solaris architecture)
4498                         ;;
4499                 esac
4500         fi
4501 fi
4502
4503 if test -z "$cf_pathlist"
4504 then
4505         # HP-UX
4506         if test x"`uname -s`" = xHP-UX
4507         then
4508                 case x`getconf LONG_BIT` in
4509                 (x64)
4510                         cf_pathlist="/usr/lib/hpux64"
4511                         ;;
4512                 (x*)
4513                         cf_pathlist="/usr/lib/hpux32"
4514                         ;;
4515                 esac
4516         fi
4517 fi
4518
4519 fi
4520
4521 # If nothing else, assume it is conventional
4522 test -z "$cf_pathlist" && cf_pathlist="/usr/lib /lib"
4523
4524 # Finally, check that this is only directories
4525 for cf_path in [$]0 $cf_pathlist
4526 do
4527         if test -d "$cf_path"; then
4528                 test -n "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath="${cf_cv_ld_searchpath} "
4529                 cf_cv_ld_searchpath="${cf_cv_ld_searchpath}${cf_path}"
4530         fi
4531 done
4532
4533 # Ensure that it is nonempty
4534 test -z "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath=/usr/lib
4535 ])
4536
4537 LD_SEARCHPATH=`echo "$cf_cv_ld_searchpath"|sed -e 's/ /|/g'`
4538 AC_SUBST(LD_SEARCHPATH)
4539 ])dnl
4540 dnl ---------------------------------------------------------------------------
4541 dnl CF_LIBRARY_PATH version: 11 updated: 2021/01/01 13:31:04
4542 dnl ---------------
4543 dnl Construct a search-list of directories for a nonstandard library-file
4544 dnl
4545 dnl Parameters
4546 dnl     $1 = the variable to return as result
4547 dnl     $2 = the package name
4548 AC_DEFUN([CF_LIBRARY_PATH],
4549 [
4550 $1=
4551 cf_library_path_list=""
4552 if test -n "${LDFLAGS}${LIBS}" ; then
4553         for cf_library_path in $LDFLAGS $LIBS
4554         do
4555                 case "$cf_library_path" in
4556                 (-L*)
4557                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
4558                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
4559                         cf_library_path_list="$cf_library_path_list [$]$1"
4560                         ;;
4561                 esac
4562         done
4563 fi
4564
4565 CF_SUBDIR_PATH($1,$2,lib)
4566
4567 $1="$cf_library_path_list [$]$1"
4568 ])dnl
4569 dnl ---------------------------------------------------------------------------
4570 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
4571 dnl ------------------
4572 AC_DEFUN([CF_LIBTOOL_VERSION],[
4573 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
4574 then
4575         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
4576 else
4577         cf_cv_libtool_version=
4578 fi
4579 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
4580 ])dnl
4581 dnl ---------------------------------------------------------------------------
4582 dnl CF_LIB_PREFIX version: 14 updated: 2021/01/01 13:31:04
4583 dnl -------------
4584 dnl Compute the library-prefix for the given host system
4585 dnl $1 = variable to set
4586 define([CF_LIB_PREFIX],
4587 [
4588         case "$cf_cv_system_name" in
4589         (OS/2*|os2*)
4590                 if test "$DFT_LWR_MODEL" = libtool; then
4591                         LIB_PREFIX='lib'
4592                 else
4593                         LIB_PREFIX=''
4594                 fi
4595                 ;;
4596         (*-msvc*)
4597                 LIB_PREFIX=''
4598                 ;;
4599         (*)     LIB_PREFIX='lib'
4600                 ;;
4601         esac
4602 ifelse($1,,,[$1=$LIB_PREFIX])
4603         AC_SUBST(LIB_PREFIX)
4604 ])dnl
4605 dnl ---------------------------------------------------------------------------
4606 dnl CF_LIB_RULES version: 100 updated: 2023/06/03 15:17:30
4607 dnl ------------
4608 dnl Append definitions and rules for the given models to the subdirectory
4609 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
4610 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
4611 dnl the corresponding makefile to list the models that we'll generate.
4612 dnl
4613 dnl For shared libraries, make a list of symbolic links to construct when
4614 dnl generating each library.  The convention used for Linux is the simplest
4615 dnl one:
4616 dnl     lib<name>.so    ->
4617 dnl     lib<name>.so.<major>    ->
4618 dnl     lib<name>.so.<maj>.<minor>
4619 dnl
4620 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
4621 AC_DEFUN([CF_LIB_RULES],
4622 [AC_REQUIRE([AC_PROG_FGREP])dnl
4623 AC_REQUIRE([CF_MAKE_PHONY])dnl
4624
4625 cf_prefix=$LIB_PREFIX
4626 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
4627
4628 case "$cf_cv_shlib_version" in
4629 (cygdll|msysdll|mingw|msvcdll)
4630         TINFO_NAME=$TINFO_ARG_SUFFIX
4631         TINFO_SUFFIX=.dll
4632         ;;
4633 esac
4634
4635 if test -n "$TINFO_SUFFIX" ; then
4636         case "$TINFO_SUFFIX" in
4637         (tw*)
4638                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
4639                 TINFO_SUFFIX=`echo "$TINFO_SUFFIX" | sed 's/^tw'$EXTRA_SUFFIX'//'`
4640                 ;;
4641         (t*)
4642                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
4643                 TINFO_SUFFIX=`echo "$TINFO_SUFFIX" | sed 's/^t'$EXTRA_SUFFIX'//'`
4644                 ;;
4645         (w*)
4646                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
4647                 TINFO_SUFFIX=`echo "$TINFO_SUFFIX" | sed 's/^w'$EXTRA_SUFFIX'//'`
4648                 ;;
4649         esac
4650 fi
4651
4652 for cf_dir in $SRC_SUBDIRS
4653 do
4654         if test ! -d "$srcdir/$cf_dir" ; then
4655                 continue
4656         elif test -f "$srcdir/$cf_dir/modules" ; then
4657
4658                 SHARED_LIB=
4659                 Libs_To_Make=
4660                 cf_awk_program=
4661                 if test -n "${cf_cv_abi_default}" && test "x${cf_cv_abi_default}" != "x5"
4662                 then
4663                         cf_awk_program="$cf_awk_program\
4664 /deprecated in ABI${cf_cv_abi_default}/ { next; }\
4665 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_default}\"); }\
4666 "
4667                 fi
4668
4669                 if test "x$WILDCARD_SYMS" = xno
4670                 then
4671                         cf_awk_program="$cf_awk_program\
4672 /[[     ]]_\\*;/ { skip=1; next; }\
4673 "
4674                 fi
4675
4676                 if test "x$cf_awk_program" != "x"
4677                 then
4678                         cat >>$cf_dir/Makefile <<CF_EOF
4679
4680 # Generated by CF_LIB_RULES
4681 resulting.map: $UNALTERED_SYMS
4682         $AWK 'BEGIN { skip = 1; last=""; } \
4683 $cf_awk_program \
4684 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
4685  skip = 0; last = \[$]\[$]0; } \
4686 END { print last; }' < "$UNALTERED_SYMS" >\[$]@
4687
4688 distclean::
4689         rm -f resulting.map
4690 CF_EOF
4691                 fi
4692
4693                 for cf_item in $cf_LIST_MODELS
4694                 do
4695                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4696                         if test "$cf_dir" = "c++"
4697                         then
4698                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4699                         else
4700                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4701                         fi
4702                         test -z "$cf_libname" && cf_libname="$cf_dir"
4703                         if test "$cf_item" = shared ; then
4704                                 if test -n "${LIB_SUFFIX}"
4705                                 then
4706                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4707                                 else
4708                                         cf_shared_suffix="$cf_suffix"
4709                                 fi
4710                                 if test "$cf_cv_do_symlinks" = yes ; then
4711                                         cf_version_name=
4712
4713                                         case "$cf_cv_shlib_version" in
4714                                         (rel)
4715                                                 cf_version_name=REL_VERSION
4716                                                 ;;
4717                                         (abi)
4718                                                 cf_version_name=ABI_VERSION
4719                                                 ;;
4720                                         esac
4721
4722                                         if test -n "$cf_version_name"
4723                                         then
4724                                                 case "$cf_cv_system_name" in
4725                                                 (darwin*)
4726                                                         # "w", etc?
4727                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
4728                                                         ;;
4729                                                 (*)
4730                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
4731                                                         ;;
4732                                                 esac
4733                                         fi
4734                                         if test -n "${USE_LIB_SUFFIX}"
4735                                         then
4736                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4737                                         else
4738                                                 cf_shared_suffix="$cf_suffix"
4739                                         fi
4740                                 fi
4741                                 # cygwin needs import library, and has unique naming convention
4742                                 # use autodetected ${cf_prefix} for import lib and static lib, but
4743                                 # use 'cyg' prefix for shared lib.
4744                                 case "$cf_cv_shlib_version" in
4745                                 (cygdll)
4746                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4747                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
4748                                         ;;
4749                                 (msysdll)
4750                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4751                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
4752                                         ;;
4753                                 (mingw)
4754                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4755                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
4756                                         ;;
4757                                 (msvcdll)
4758                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4759                                         cf_add_lib="../lib/${cf_libname}${cf_cygsuf}"
4760                                         ;;
4761                                 (*)
4762                                         cf_add_lib=
4763                                         ;;
4764                                 esac
4765                                 if test -n "$cf_add_lib"
4766                                 then
4767                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4768                                         continue
4769                                 fi
4770                         fi
4771                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
4772                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4773                 done
4774
4775                 if test "$cf_dir" = ncurses ; then
4776                         cf_subsets="$LIB_SUBSETS"
4777                         cf_r_parts="$cf_subsets"
4778                         cf_liblist="$Libs_To_Make"
4779
4780                         while test -n "$cf_r_parts"
4781                         do
4782                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
4783                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
4784                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
4785                                         cf_add_lib=
4786                                         case "$cf_l_parts" in
4787                                         (*termlib*)
4788                                                 cf_add_lib=`echo "$cf_liblist" |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
4789                                                 ;;
4790                                         (*ticlib*)
4791                                                 cf_add_lib=`echo "$cf_liblist" |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
4792                                                 ;;
4793                                         (*)
4794                                                 break
4795                                                 ;;
4796                                         esac
4797                                         if test -n "$cf_add_lib"; then
4798                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
4799                                         fi
4800                                 else
4801                                         break
4802                                 fi
4803                         done
4804                 else
4805                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
4806                 fi
4807
4808                 if test "$cf_dir" = c++; then
4809                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
4810                                 cf_list=
4811                                 for cf_item in $Libs_To_Make
4812                                 do
4813                                         case "$cf_item" in
4814                                         (*.a)
4815                                                 ;;
4816                                         (*)
4817                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
4818                                                 ;;
4819                                         esac
4820                                         for cf_test in $cf_list
4821                                         do
4822                                                 if test "$cf_test" = "$cf_item"
4823                                                 then
4824                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
4825                                                         cf_item=
4826                                                         break
4827                                                 fi
4828                                         done
4829                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
4830                                 done
4831                                 Libs_To_Make="$cf_list"
4832                         fi
4833                 fi
4834
4835                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
4836                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
4837                         "$cf_dir/Makefile" >$cf_dir/Makefile.out
4838                 mv "$cf_dir/Makefile.out" "$cf_dir/Makefile"
4839
4840                 $AWK -f "$srcdir/mk-0th.awk" \
4841                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
4842                         "$srcdir/$cf_dir/modules" >>$cf_dir/Makefile
4843
4844                 for cf_subset in $cf_subsets
4845                 do
4846                         cf_subdirs=
4847                         for cf_item in $cf_LIST_MODELS
4848                         do
4849
4850                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
4851                         CF_UPPER(cf_ITEM,$cf_item)
4852
4853                         CXX_MODEL=$cf_ITEM
4854                         if test "$CXX_MODEL" = SHARED; then
4855                                 case "$cf_cv_shlib_version" in
4856                                 (cygdll|msysdll|mingw|msvcdll)
4857                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
4858                                         with_shared_cxx=yes
4859                                         ;;
4860                                 (*)
4861                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
4862                                         ;;
4863                                 esac
4864                         fi
4865
4866                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4867                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
4868
4869                         # Test for case where we build libtinfo with a different name.
4870                         cf_libname=$cf_dir
4871                         if test "$cf_dir" = ncurses ; then
4872                                 case "$cf_subset" in
4873                                 (*base*)
4874                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
4875                                         ;;
4876                                 (*termlib*)
4877                                         cf_libname=$TINFO_LIB_SUFFIX
4878                                         ;;
4879                                 (ticlib*)
4880                                         cf_libname=$TICS_LIB_SUFFIX
4881                                         ;;
4882                                 esac
4883                         elif test "$cf_dir" = c++ ; then
4884                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4885                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4886                         else
4887                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4888                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4889                         fi
4890                         if test -n "${USE_ARG_SUFFIX}" ; then
4891                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
4892                                 cf_suffix=`echo "$cf_suffix" |sed -e "s%^${USE_LIB_SUFFIX}%%"`
4893                         fi
4894
4895                         # These dependencies really are for development, not
4896                         # builds, but they are useful in porting, too.
4897                         cf_depend="../include/ncurses_cfg.h"
4898                         if test "$srcdir" = "."; then
4899                                 cf_reldir="."
4900                         else
4901                                 cf_reldir="\${srcdir}"
4902                         fi
4903
4904                         if test -f "$srcdir/$cf_dir/$cf_dir.priv.h" ; then
4905                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
4906                         elif test -f "$srcdir/$cf_dir/curses.priv.h" ; then
4907                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
4908                         fi
4909
4910                         cf_dir_suffix=
4911                         old_cf_suffix="$cf_suffix"
4912                         if test "$cf_cv_shlib_version_infix" = yes ; then
4913                         if test -n "$USE_LIB_SUFFIX" ; then
4914                                 case "$USE_LIB_SUFFIX" in
4915                                 (tw*)
4916                                         cf_libname=`echo "$cf_libname" | sed 's/tw'$EXTRA_SUFFIX'$//'`
4917                                         cf_suffix=`echo "$cf_suffix" | sed 's/^tw'$EXTRA_SUFFIX'//'`
4918                                         cf_dir_suffix=tw$EXTRA_SUFFIX
4919                                         ;;
4920                                 (t*)
4921                                         cf_libname=`echo "$cf_libname" | sed 's/t'$EXTRA_SUFFIX'$//'`
4922                                         cf_suffix=`echo "$cf_suffix" | sed 's/^t'$EXTRA_SUFFIX'//'`
4923                                         cf_dir_suffix=t$EXTRA_SUFFIX
4924                                         ;;
4925                                 (w*)
4926                                         cf_libname=`echo "$cf_libname" | sed 's/w'$EXTRA_SUFFIX'$//'`
4927                                         cf_suffix=`echo "$cf_suffix" | sed 's/^w'$EXTRA_SUFFIX'//'`
4928                                         cf_dir_suffix=w$EXTRA_SUFFIX
4929                                         ;;
4930                                 (*)
4931                                         cf_libname=`echo "$cf_libname" | sed 's/'$EXTRA_SUFFIX'$//'`
4932                                         cf_suffix=`echo "$cf_suffix" | sed 's/^'$EXTRA_SUFFIX'//'`
4933                                         cf_dir_suffix=$EXTRA_SUFFIX
4934                                         ;;
4935                                 esac
4936                         fi
4937                         fi
4938
4939                         $AWK -f "$srcdir/mk-1st.awk" \
4940                                 name=${cf_libname}${cf_dir_suffix} \
4941                                 traces=$LIB_TRACING \
4942                                 MODEL=$cf_ITEM \
4943                                 CXX_MODEL=$CXX_MODEL \
4944                                 LIB_SUFFIX=$LIB_SUFFIX \
4945                                 USE_LIB_SUFFIX=$USE_LIB_SUFFIX \
4946                                 make_phony="${cf_cv_make_PHONY:-no}" \
4947                                 model=$cf_subdir \
4948                                 prefix=$cf_prefix \
4949                                 suffix=$cf_suffix \
4950                                 subset=$cf_subset \
4951                                 driver=$cf_cv_term_driver \
4952                                 SymLink="$LN_S" \
4953                                 TermlibRoot=$TINFO_NAME \
4954                                 TermlibSuffix=$TINFO_SUFFIX \
4955                                 ShlibVer=$cf_cv_shlib_version \
4956                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
4957                                 ReLink=${cf_cv_do_relink:-no} \
4958                                 ReRanlib=${cf_cv_do_reranlib:-yes} \
4959                                 DoLinks=$cf_cv_do_symlinks \
4960                                 rmSoLocs=$cf_cv_rm_so_locs \
4961                                 ldconfig="$LDCONFIG" \
4962                                 overwrite=$WITH_OVERWRITE \
4963                                 depend="$cf_depend" \
4964                                 host="$host" \
4965                                 libtool_version="$LIBTOOL_VERSION" \
4966                                 "$srcdir/$cf_dir/modules" >>$cf_dir/Makefile
4967
4968                         cf_suffix="$old_cf_suffix"
4969
4970                         for cf_subdir2 in $cf_subdirs lib
4971                         do
4972                                 test "$cf_subdir" = "$cf_subdir2" && break
4973                         done
4974                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
4975                         $AWK -f "$srcdir/mk-2nd.awk" \
4976                                 name=$cf_dir \
4977                                 traces=$LIB_TRACING \
4978                                 MODEL=$cf_ITEM \
4979                                 model=$cf_subdir \
4980                                 subset=$cf_subset \
4981                                 srcdir=$srcdir \
4982                                 echo=$WITH_ECHO \
4983                                 crenames=$cf_cv_prog_CC_c_o \
4984                                 cxxrenames=$cf_cv_prog_CXX_c_o \
4985                                 "$srcdir/$cf_dir/modules" >>$cf_dir/Makefile
4986                         cf_subdirs="$cf_subdirs $cf_subdir"
4987                         done
4988                 done
4989         fi
4990
4991         echo '  ( cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@ )' >>Makefile
4992 done
4993
4994 echo >> Makefile
4995 echo '# generated by CF_LIB_RULES' >> Makefile
4996
4997 if test "x$cf_cv_make_PHONY" = xyes ; then
4998         cat >> Makefile <<-CF_EOF
4999
5000         .PHONY :        libs
5001         .PHONY :        lintlib
5002         .PHONY :        install.includes
5003         .PHONY :        uninstall.includes
5004         .PHONY :        install.libs
5005         .PHONY :        uninstall.libs
5006 CF_EOF
5007 fi
5008
5009 for cf_dir in $SRC_SUBDIRS
5010 do
5011         if test ! -d "$srcdir/$cf_dir" ; then
5012                 continue
5013         fi
5014
5015         if test -f "$cf_dir/Makefile" ; then
5016                 case "$cf_dir" in
5017                 (Ada95)
5018                         echo 'libs \' >> Makefile
5019                         echo 'install.libs \' >> Makefile
5020                         echo 'uninstall.libs ::' >> Makefile
5021                         echo '  ( cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@ )' >> Makefile
5022                         ;;
5023                 esac
5024         fi
5025
5026         if test -f "$srcdir/$cf_dir/modules" ; then
5027
5028                 if test "x$cf_cv_make_PHONY" = xyes ; then
5029                         cat >> Makefile <<-CF_EOF
5030
5031                         .PHONY :        install.$cf_dir
5032                         .PHONY :        uninstall.$cf_dir
5033 CF_EOF
5034                 fi
5035
5036                 echo >> Makefile
5037                 if test -f "$srcdir/$cf_dir/headers" ; then
5038 cat >> Makefile <<CF_EOF
5039 install.includes \\
5040 uninstall.includes \\
5041 CF_EOF
5042                 fi
5043
5044 cat >> Makefile <<CF_EOF
5045 lint \\
5046 libs \\
5047 lintlib \\
5048 install.libs \\
5049 uninstall.libs \\
5050 install.$cf_dir \\
5051 uninstall.$cf_dir ::
5052         ( cd "$cf_dir" && \${MAKE} \${TOP_MFLAGS} \[$]@ )
5053 CF_EOF
5054         elif test -f "$srcdir/$cf_dir/headers" ; then
5055 cat >> Makefile <<CF_EOF
5056
5057 libs \\
5058 install.libs \\
5059 uninstall.libs \\
5060 install.includes \\
5061 uninstall.includes ::
5062         ( cd "$cf_dir" && \${MAKE} \${TOP_MFLAGS} \[$]@ )
5063 CF_EOF
5064 fi
5065 done
5066
5067 if test "x$cf_cv_make_PHONY" = xyes ; then
5068         cat >> Makefile <<-CF_EOF
5069
5070         .PHONY :        install.data
5071         .PHONY :        uninstall.data
5072 CF_EOF
5073 fi
5074
5075 if test "x$cf_with_db_install" = xyes; then
5076 cat >> Makefile <<CF_EOF
5077
5078 install.libs uninstall.libs \\
5079 install.data uninstall.data ::
5080 $MAKE_TERMINFO  ( cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@ )
5081 CF_EOF
5082 else
5083 cat >> Makefile <<CF_EOF
5084
5085 install.libs uninstall.libs ::
5086         ( cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@ )
5087 CF_EOF
5088 fi
5089
5090 if test "x$cf_with_manpages" = xyes; then
5091
5092 if test "x$cf_cv_make_PHONY" = xyes ; then
5093         cat >> Makefile <<-CF_EOF
5094
5095         .PHONY :        install.man
5096         .PHONY :        uninstall.man
5097 CF_EOF
5098 fi
5099
5100 cat >> Makefile <<CF_EOF
5101
5102 install.man \\
5103 uninstall.man ::
5104         ( cd man && \${MAKE} \${TOP_MFLAGS} \[$]@ )
5105 CF_EOF
5106 fi
5107
5108 cat >> Makefile <<CF_EOF
5109
5110 distclean ::
5111         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
5112         rm -f headers.sh headers.sed mk_shared_lib.sh
5113         rm -f edit_man.* man_alias.* *.tmp
5114         rm -rf \${DIRS_TO_MAKE}
5115 CF_EOF
5116
5117 dnl If we're installing into a subdirectory of /usr/include, etc., we should
5118 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
5119 dnl anything, and will make it more standardized.  It's awkward to decide this
5120 dnl at configuration because of quoting, so we'll simply make all headers
5121 dnl installed via a script that can do the right thing.
5122
5123 rm -f headers.sed headers.sh
5124
5125 dnl ( generating this script makes the makefiles a little tidier :-)
5126 echo creating headers.sh
5127 cat >headers.sh <<CF_EOF
5128 #! $SHELL
5129 # This shell script is generated by the 'configure' script.  It is invoked in a
5130 # subdirectory of the build tree.  It generates a sed-script in the parent
5131 # directory that is used to adjust includes for header files that reside in a
5132 # subdirectory of /usr/include, etc.
5133 PRG=""
5134 while test \[$]# != 3
5135 do
5136 PRG="\$PRG \[$]1"; shift
5137 done
5138 DST=\[$]1
5139 REF=\[$]2
5140 SRC=\[$]3
5141 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
5142 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
5143 echo installing \$SRC in \$DST
5144 CF_EOF
5145
5146 if test "$WITH_CURSES_H" = yes; then
5147         cat >>headers.sh <<CF_EOF
5148 case \$DST in
5149 (/*/include/*)
5150         END=\`basename \$DST\`
5151         for i in \`cat \$REF/../*/headers |${FGREP-fgrep} -v "#"\`
5152         do
5153                 NAME=\`basename \$i\`
5154                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
5155         done
5156         ;;
5157 (*)
5158         echo "" >> \$TMPSED
5159         ;;
5160 esac
5161 CF_EOF
5162
5163 else
5164         cat >>headers.sh <<CF_EOF
5165 case \$DST in
5166 (/*/include/*)
5167         END=\`basename \$DST\`
5168         for i in \`cat \$REF/../*/headers |${FGREP-fgrep} -v "#"\`
5169         do
5170                 NAME=\`basename \$i\`
5171                 if test "\$NAME" = "curses.h"
5172                 then
5173                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
5174                         NAME=ncurses.h
5175                 fi
5176                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
5177         done
5178         ;;
5179 (*)
5180         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
5181         ;;
5182 esac
5183 CF_EOF
5184 fi
5185 cat >>headers.sh <<CF_EOF
5186 rm -f \$TMPSRC
5187 sed -f \$TMPSED \$SRC > \$TMPSRC
5188 NAME=\`basename \$SRC\`
5189 CF_EOF
5190 if test "$WITH_CURSES_H" != yes; then
5191         cat >>headers.sh <<CF_EOF
5192 test "\$NAME" = "curses.h" && NAME=ncurses.h
5193 CF_EOF
5194 fi
5195 cat >>headers.sh <<CF_EOF
5196 # Just in case someone gzip'd manpages, remove the conflicting copy.
5197 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
5198
5199 eval \$PRG \$TMPSRC \$DST/\$NAME
5200 rm -f \$TMPSRC \$TMPSED
5201 CF_EOF
5202
5203 chmod 0755 headers.sh
5204
5205 for cf_dir in $SRC_SUBDIRS
5206 do
5207         if test ! -d "$srcdir/$cf_dir" ; then
5208                 continue
5209         fi
5210
5211         if test -f "$srcdir/$cf_dir/headers" ; then
5212                 $AWK -f "$srcdir/mk-hdr.awk" \
5213                         subset="$LIB_SUBSETS" \
5214                         compat="$WITH_CURSES_H" \
5215                         "$srcdir/$cf_dir/headers" >>$cf_dir/Makefile
5216         fi
5217
5218         if test -f "$srcdir/$cf_dir/modules" ; then
5219                 if test "$cf_dir" != "c++" ; then
5220                         if test "x$cf_cv_make_PHONY" = xyes ; then
5221                                 cat >> $cf_dir/Makefile <<-CF_EOF
5222
5223                                 .PHONY :        depend
5224 CF_EOF
5225                         fi
5226
5227                         cat >>$cf_dir/Makefile <<"CF_EOF"
5228 depend : ${AUTO_SRC}
5229         makedepend -- ${CPPFLAGS} -- ${C_SRC}
5230
5231 # DO NOT DELETE THIS LINE -- make depend depends on it.
5232 CF_EOF
5233                 fi
5234         fi
5235 done
5236 AC_SUBST(Libs_To_Make)
5237 ])dnl
5238 dnl ---------------------------------------------------------------------------
5239 dnl CF_LIB_SONAME version: 9 updated: 2021/01/04 18:48:01
5240 dnl -------------
5241 dnl Find the and soname for the given shared library.  Set the cache variable
5242 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
5243 dnl variable to "unknown".
5244 dnl
5245 dnl $1 = headers
5246 dnl $2 = code
5247 dnl $3 = library name
5248 AC_DEFUN([CF_LIB_SONAME],
5249 [AC_REQUIRE([AC_PROG_FGREP])dnl
5250
5251 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
5252
5253 cf_cv_$3_soname=unknown
5254 if test "$cross_compiling" != yes ; then
5255 cat >conftest.$ac_ext <<CF_EOF
5256 $1
5257 int main(void)
5258 {
5259 $2
5260         ${cf_cv_main_return:-return}(0);
5261 }
5262 CF_EOF
5263 cf_save_LIBS="$LIBS"
5264         CF_ADD_LIB($3)
5265         if AC_TRY_EVAL(ac_compile) ; then
5266                 if AC_TRY_EVAL(ac_link) ; then
5267                         cf_cv_$3_soname="`ldd \"conftest$ac_exeext\" 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | ${FGREP-fgrep} lib$3.`"
5268                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
5269                 fi
5270         fi
5271 rm -rf ./conftest*
5272 LIBS="$cf_save_LIBS"
5273 fi
5274 ])
5275 ])
5276 dnl ---------------------------------------------------------------------------
5277 dnl CF_LIB_SUFFIX version: 28 updated: 2021/01/01 16:53:59
5278 dnl -------------
5279 dnl Compute the library file-suffix from the given model name
5280 dnl $1 = model name
5281 dnl $2 = variable to set (the nominal library suffix)
5282 dnl $3 = dependency variable to set (actual filename)
5283 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
5284 AC_DEFUN([CF_LIB_SUFFIX],
5285 [
5286         case X$1 in
5287         (Xlibtool)
5288                 $2='.la'
5289                 $3=[$]$2
5290                 ;;
5291         (Xdebug)
5292                 case "$cf_cv_system_name" in
5293                 (*-msvc*)
5294                         $2='_g.lib'
5295                         ;;
5296                 (*)
5297                         $2='_g.a'
5298                         ;;
5299                 esac
5300                 $3=[$]$2
5301                 ;;
5302         (Xprofile)
5303                 case "$cf_cv_system_name" in
5304                 (*-msvc*)
5305                         $2='_p.lib'
5306                         ;;
5307                 (*)
5308                         $2='_p.a'
5309                         ;;
5310                 esac
5311                 $3=[$]$2
5312                 ;;
5313         (Xshared)
5314                 case "$cf_cv_system_name" in
5315                 (aix[[5-7]]*)
5316                         $2='.so'
5317                         $3=[$]$2
5318                         ;;
5319                 (*-msvc*)
5320                         $2='.dll'
5321                         $3='.dll.lib'
5322                         ;;
5323                 (cygwin*|msys*|mingw*)
5324                         $2='.dll'
5325                         $3='.dll.a'
5326                         ;;
5327                 (darwin*)
5328                         $2='.dylib'
5329                         $3=[$]$2
5330                         ;;
5331                 (hpux*)
5332                         case "$target" in
5333                         (ia64*)
5334                                 $2='.so'
5335                                 $3=[$]$2
5336                                 ;;
5337                         (*)
5338                                 $2='.sl'
5339                                 $3=[$]$2
5340                                 ;;
5341                         esac
5342                         ;;
5343                 (*)
5344                         $2='.so'
5345                         $3=[$]$2
5346                         ;;
5347                 esac
5348                 ;;
5349         (*)
5350                 case "$target" in
5351                 (*-msvc*)
5352                         $2='.lib'
5353                         ;;
5354                 (*)
5355                         $2='.a'
5356                         ;;
5357                 esac
5358                 $3=[$]$2
5359                 ;;
5360         esac
5361         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
5362         then
5363                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
5364                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
5365         fi
5366 ])dnl
5367 dnl ---------------------------------------------------------------------------
5368 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
5369 dnl -----------
5370 dnl Compute the string to append to -library from the given model name
5371 dnl $1 = model name
5372 dnl $2 = variable to set
5373 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
5374 AC_DEFUN([CF_LIB_TYPE],
5375 [
5376         case $1 in
5377         (libtool) $2=''   ;;
5378         (normal)  $2=''   ;;
5379         (debug)   $2='_g' ;;
5380         (profile) $2='_p' ;;
5381         (shared)  $2=''   ;;
5382         esac
5383         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
5384 ])dnl
5385 dnl ---------------------------------------------------------------------------
5386 dnl CF_LINK_DATAONLY version: 15 updated: 2023/12/03 10:03:10
5387 dnl ----------------
5388 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
5389 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
5390 dnl have to provide wrappers for global tables to ensure they're linked
5391 dnl properly.
5392 AC_DEFUN([CF_LINK_DATAONLY],
5393 [
5394 AC_MSG_CHECKING([if data-only library module links])
5395 AC_CACHE_VAL(cf_cv_link_dataonly,[
5396         rm -f conftest.a
5397         cat >conftest.$ac_ext <<EOF
5398 #line __oline__ "configure"
5399 int     testdata[[3]] = { 123, 456, 789 };
5400 EOF
5401         if AC_TRY_EVAL(ac_compile) ; then
5402                 mv conftest.o data.o && \
5403                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
5404         fi
5405         rm -f conftest.$ac_ext data.o
5406         cat >conftest.$ac_ext <<EOF
5407 #line __oline__ "configure"
5408 extern int testfunc(void);
5409 #if defined(NeXT)
5410 int     testfunc(void)
5411 {
5412         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
5413 }
5414 #else
5415 extern int testdata[[3]];
5416 int     testfunc(void)
5417 {
5418         return testdata[[0]] == 123
5419            &&  testdata[[1]] == 456
5420            &&  testdata[[2]] == 789;
5421 }
5422 #endif
5423 EOF
5424         if AC_TRY_EVAL(ac_compile); then
5425                 mv conftest.o func.o && \
5426                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
5427         fi
5428         rm -f conftest.$ac_ext func.o
5429         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
5430         cf_saveLIBS="$LIBS"
5431         LIBS="conftest.a $LIBS"
5432         AC_TRY_RUN([
5433         extern int testfunc(void);
5434         int main(void)
5435         {
5436                 ${cf_cv_main_return:-return} (!testfunc());
5437         }
5438         ],
5439         [cf_cv_link_dataonly=yes],
5440         [cf_cv_link_dataonly=no],
5441         [cf_cv_link_dataonly=unknown])
5442         LIBS="$cf_saveLIBS"
5443         ])
5444 AC_MSG_RESULT($cf_cv_link_dataonly)
5445
5446 if test "$cf_cv_link_dataonly" = no ; then
5447         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
5448         BROKEN_LINKER=1
5449 fi
5450 AC_SUBST(BROKEN_LINKER)
5451
5452 ])dnl
5453 dnl ---------------------------------------------------------------------------
5454 dnl CF_LINK_FUNCS version: 13 updated: 2023/12/03 09:24:04
5455 dnl -------------
5456 dnl Most Unix systems have both link and symlink, a few don't have symlink.
5457 dnl A few non-Unix systems implement symlink, but not link.
5458 dnl A few non-systems implement neither (or have nonfunctional versions).
5459 dnl
5460 dnl This allows for a 2-second difference in modification times to allow for
5461 dnl some marginal NFS implementations.
5462 AC_DEFUN([CF_LINK_FUNCS],
5463 [
5464 AC_CHECK_HEADERS( \
5465 unistd.h \
5466 )
5467 AC_CHECK_FUNCS( \
5468         remove \
5469         unlink )
5470
5471 if test "$cross_compiling" = yes ; then
5472         AC_CHECK_FUNCS( \
5473                 link \
5474                 symlink )
5475 else
5476         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
5477                 cf_cv_link_funcs=
5478                 for cf_func in link symlink ; do
5479                         AC_TRY_RUN([
5480 $ac_includes_default
5481
5482 int main(void)
5483 {
5484         int fail = 0;
5485         char src[] = "conftest.tmp";
5486         char dst[] = "conftest.chk";
5487         struct stat src_sb, dst_sb;
5488         FILE *fp = fopen(src, "w");
5489         if (fp == 0) { fail = 3; } else {
5490                 fclose(fp); stat(src, &src_sb);
5491                 if ($cf_func(src, dst) < 0) {
5492                         fail = 1;
5493                 } else if (stat(dst, &dst_sb) < 0) {
5494                         fail = 2;
5495                 } else {
5496                         long diff = (dst_sb.st_mtime - src_sb.st_mtime);
5497                         if (diff < 0) diff = -diff;
5498                         if (diff > 2) fail = 3;
5499                 }
5500         }
5501 #ifdef HAVE_UNLINK
5502         unlink(dst); unlink(src);
5503 #else
5504         remove(dst); remove(src);
5505 #endif
5506         ${cf_cv_main_return:-return} (fail);
5507 }
5508                         ],[
5509                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
5510                         eval 'ac_cv_func_'$cf_func'=yes'],[
5511                         eval 'ac_cv_func_'$cf_func'=no'],[
5512                         eval 'ac_cv_func_'$cf_func'=error'])
5513                 done
5514                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
5515         ])
5516         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
5517         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
5518 fi
5519 ])dnl
5520 dnl ---------------------------------------------------------------------------
5521 dnl CF_MAKEFLAGS version: 21 updated: 2021/09/04 06:47:34
5522 dnl ------------
5523 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
5524 dnl options to lower-levels.  It is very useful for "make -n" -- if we have it.
5525 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
5526 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
5527 AC_DEFUN([CF_MAKEFLAGS],
5528 [AC_REQUIRE([AC_PROG_FGREP])dnl
5529
5530 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
5531         cf_cv_makeflags=''
5532         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
5533         do
5534                 cat >cf_makeflags.tmp <<CF_EOF
5535 SHELL = $SHELL
5536 all :
5537         @ echo '.$cf_option'
5538 CF_EOF
5539                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | ${FGREP-fgrep} -v "ing directory" | sed -e 's,[[  ]]*$,,'`
5540                 case "$cf_result" in
5541                 (.*k|.*kw)
5542                         cf_result="`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`"
5543                         case "$cf_result" in
5544                         (.*CC=*)        cf_cv_makeflags=
5545                                 ;;
5546                         (*)     cf_cv_makeflags=$cf_option
5547                                 ;;
5548                         esac
5549                         break
5550                         ;;
5551                 (.-)
5552                         ;;
5553                 (*)
5554                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
5555                         ;;
5556                 esac
5557         done
5558         rm -f cf_makeflags.tmp
5559 ])
5560
5561 AC_SUBST(cf_cv_makeflags)
5562 ])dnl
5563 dnl ---------------------------------------------------------------------------
5564 dnl CF_MAKE_PHONY version: 3 updated: 2021/01/08 16:08:21
5565 dnl -------------
5566 dnl Check if the make-program handles a ".PHONY" target, e.g,. a target which
5567 dnl acts as a placeholder.
5568 dnl
5569 dnl The ".PHONY" feature was proposed in 2011 here
5570 dnl     https://www.austingroupbugs.net/view.php?id=523
5571 dnl and is scheduled for release in P1003.1 Issue 8 (late 2022).
5572 dnl
5573 dnl This is not supported by SVr4 make (or SunOS 4, 4.3SD, etc), but works with
5574 dnl a few others (i.e., GNU make and the non-POSIX "BSD" make):
5575 dnl
5576 dnl + This is a GNU make feature (since April 1988, but in turn from binutils,
5577 dnl   date unspecified).
5578 dnl
5579 dnl + It was adopted in NetBSD make in June 1995.
5580 dnl
5581 dnl + The other BSD make programs are derived from the NetBSD make (and for
5582 dnl   that reason are not actually different "implementations").
5583 dnl
5584 dnl + Some features of NetBSD make were actually adapted from pmake, which
5585 dnl   began as a modified GNU make starting in 1993.
5586 dnl
5587 dnl + Version 3.8 of the dmake program in January 1992 also implemented this
5588 dnl   GNU make extension, but is less well known than the BSD make.
5589 AC_DEFUN([CF_MAKE_PHONY],[
5590 AC_CACHE_CHECK(for \".PHONY\" make-support, cf_cv_make_PHONY,[
5591         rm -rf conftest*
5592         (
5593                 mkdir conftest || exit 1
5594                 cd conftest
5595                 cat >makefile <<'CF_EOF'
5596 .PHONY: always
5597 DATA=0
5598 always: always.out
5599         @echo "** making [$]@ [$](DATA)"
5600 once: once.out
5601         @echo "** making [$]@ [$](DATA)"
5602 always.out:
5603         @echo "** making [$]@ [$](DATA)"
5604         echo [$](DATA) > [$]@
5605 once.out:
5606         @echo "** making [$]@ [$](DATA)"
5607         echo [$](DATA) > [$]@
5608 CF_EOF
5609                 for cf_data in 1 2 3
5610                 do
5611                         ${MAKE:-make} always DATA=$cf_data
5612                         ${MAKE:-make} once   DATA=$cf_data
5613                         ${MAKE:-make} -t always once
5614                         if test -f always ; then
5615                                 echo "no (case 1)" > ../conftest.tmp
5616                         elif test ! -f always.out ; then
5617                                 echo "no (case 2)" > ../conftest.tmp
5618                         elif test ! -f once.out ; then
5619                                 echo "no (case 3)" > ../conftest.tmp
5620                         elif ! cmp -s always.out once.out ; then
5621                                 echo "no (case 4)" > ../conftest.tmp
5622                                 diff always.out once.out
5623                         else
5624                                 cf_check="`cat always.out`"
5625                                 if test "x$cf_check" != "x$cf_data" ; then
5626                                         echo "no (case 5)" > ../conftest.tmp
5627                                 else
5628                                         echo yes > ../conftest.tmp
5629                                         rm -f ./*.out
5630                                         continue
5631                                 fi
5632                         fi
5633                         break
5634                 done
5635         ) >&AC_FD_CC 2>&1
5636         cf_cv_make_PHONY="`cat conftest.tmp`"
5637         rm -rf conftest*
5638 ])
5639 MAKE_NO_PHONY="#"
5640 MAKE_PHONY="#"
5641 test "x$cf_cv_make_PHONY" = xyes && MAKE_PHONY=
5642 test "x$cf_cv_make_PHONY" != xyes && MAKE_NO_PHONY=
5643 AC_SUBST(MAKE_NO_PHONY)
5644 AC_SUBST(MAKE_PHONY)
5645 ])dnl
5646 dnl ---------------------------------------------------------------------------
5647 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
5648 dnl ------------
5649 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
5650 dnl a monocase filesystem.
5651 AC_DEFUN([CF_MAKE_TAGS],[
5652 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
5653
5654 AC_CHECK_PROGS(CTAGS, exctags ctags)
5655 AC_CHECK_PROGS(ETAGS, exetags etags)
5656
5657 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
5658
5659 if test "$cf_cv_mixedcase" = yes ; then
5660         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
5661 else
5662         MAKE_UPPER_TAGS=no
5663 fi
5664
5665 if test "$MAKE_UPPER_TAGS" = yes ; then
5666         MAKE_UPPER_TAGS=
5667 else
5668         MAKE_UPPER_TAGS="#"
5669 fi
5670
5671 if test "$MAKE_LOWER_TAGS" = yes ; then
5672         MAKE_LOWER_TAGS=
5673 else
5674         MAKE_LOWER_TAGS="#"
5675 fi
5676
5677 AC_SUBST(CTAGS)
5678 AC_SUBST(ETAGS)
5679
5680 AC_SUBST(MAKE_UPPER_TAGS)
5681 AC_SUBST(MAKE_LOWER_TAGS)
5682 ])dnl
5683 dnl ---------------------------------------------------------------------------
5684 dnl CF_MANPAGE_FORMAT version: 18 updated: 2023/05/19 18:35:02
5685 dnl -----------------
5686 dnl Option to allow user to override automatic configuration of manpage format.
5687 dnl There are several special cases:
5688 dnl
5689 dnl     compress - man checks for, can display compressed files
5690 dnl     bzip2 - man checks for, can display bzip2'd files
5691 dnl     gzip - man checks for, can display gzip'd files
5692 dnl     xz - man checks for, can display xz'd files
5693 dnl
5694 dnl     BSDI - files in the cat-directories are suffixed ".0"
5695 dnl     formatted - installer should format (put files in cat-directory)
5696 dnl     catonly - installer should only format, e.g., for a turnkey system.
5697 dnl
5698 dnl There are other configurations which this macro does not test, e.g., HPUX's
5699 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
5700 dnl convention would not match our use).
5701 AC_DEFUN([CF_MANPAGE_FORMAT],
5702 [
5703 AC_REQUIRE([CF_PATHSEP])
5704 AC_MSG_CHECKING(format of man-pages)
5705
5706 AC_ARG_WITH(manpage-format,
5707         [  --with-manpage-format   specify manpage-format: gzip/compress/bzip2/xz,
5708                           BSDI/normal and optionally formatted/catonly,
5709                           e.g., gzip,formatted],
5710         [MANPAGE_FORMAT=$withval],
5711         [MANPAGE_FORMAT=unknown])
5712
5713 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
5714 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
5715
5716 cf_unknown=
5717
5718 case "$MANPAGE_FORMAT" in
5719 (unknown)
5720         if test -z "$MANPATH" ; then
5721                 MANPATH="/usr/man:/usr/share/man"
5722         fi
5723
5724         # look for the 'date' man-page (it is most likely to be installed!)
5725         MANPAGE_FORMAT=
5726         cf_preform="no"
5727         cf_catonly="yes"
5728         cf_example="date"
5729
5730         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
5731         for cf_dir in $MANPATH; do
5732                 test -z "$cf_dir" && cf_dir=/usr/man
5733                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
5734                 do
5735                         cf_test=`echo "$cf_name" | sed -e 's/*//'`
5736                         if test "x$cf_test" = "x$cf_name" ; then
5737
5738                                 case "$cf_name" in
5739                                 (*.bz2) MANPAGE_FORMAT="$MANPAGE_FORMAT bzip2";;
5740                                 (*.xz)  MANPAGE_FORMAT="$MANPAGE_FORMAT xz";;
5741                                 (*.gz)  MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
5742                                 (*.Z)   MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
5743                                 (*.0)   MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
5744                                 (*)     MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
5745                                 esac
5746
5747                                 case "$cf_name" in
5748                                 ($cf_dir/man*)
5749                                         cf_catonly=no
5750                                         ;;
5751                                 ($cf_dir/cat*)
5752                                         cf_preform=yes
5753                                         ;;
5754                                 esac
5755                                 break
5756                         fi
5757
5758                         # if we found a match in either man* or cat*, stop looking
5759                         if test -n "$MANPAGE_FORMAT" ; then
5760                                 cf_found=no
5761                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
5762                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
5763                                 case "$cf_name" in
5764                                 ($cf_dir/cat*)
5765                                         cf_found=yes
5766                                         ;;
5767                                 esac
5768                                 test "$cf_found" = yes && break
5769                         fi
5770                 done
5771                 # only check the first directory in $MANPATH where we find manpages
5772                 if test -n "$MANPAGE_FORMAT" ; then
5773                         break
5774                 fi
5775         done
5776         # if we did not find the example, just assume it is normal
5777         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
5778         IFS="$ac_save_ifs"
5779         ;;
5780 (*)
5781         for cf_option in $MANPAGE_FORMAT; do
5782         case "$cf_option" in
5783         (xz|bzip2|gzip|compress|BSDI|normal|formatted|catonly)
5784                 ;;
5785         (*)
5786                 cf_unknown="$cf_unknown $cf_option"
5787                 ;;
5788         esac
5789         done
5790         ;;
5791 esac
5792
5793 AC_MSG_RESULT($MANPAGE_FORMAT)
5794 if test -n "$cf_unknown" ; then
5795         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
5796 fi
5797
5798 cf_manpage_format=no
5799 cf_manpage_inboth=no
5800 cf_manpage_so_strip=
5801 cf_manpage_compress=
5802
5803 for cf_item in $MANPAGE_FORMAT
5804 do
5805 case "$cf_item" in
5806 (catonly)
5807         cf_manpage_format=yes
5808         cf_manpage_inboth=no
5809         ;;
5810 (formatted)
5811         cf_manpage_format=yes
5812         cf_manpage_inboth=yes
5813         ;;
5814 (compress)
5815         cf_manpage_so_strip="Z"
5816         cf_manpage_compress=compress
5817         ;;
5818 (gzip)
5819         cf_manpage_so_strip="gz"
5820         cf_manpage_compress=gzip
5821         ;;
5822 (bzip2)
5823         cf_manpage_so_strip="bz2"
5824         cf_manpage_compress=bzip2
5825         ;;
5826 (xz)
5827         cf_manpage_so_strip="xz"
5828         cf_manpage_compress=xz
5829         ;;
5830 esac
5831 done
5832
5833 AC_SUBST(cf_manpage_format)
5834 AC_SUBST(cf_manpage_inboth)
5835 AC_SUBST(cf_manpage_so_strip)
5836 AC_SUBST(cf_manpage_compress)
5837
5838 ])dnl
5839 dnl ---------------------------------------------------------------------------
5840 dnl CF_MANPAGE_RENAMES version: 17 updated: 2022/10/23 07:46:29
5841 dnl ------------------
5842 dnl The Debian people have their own naming convention for manpages.  This
5843 dnl option lets us override the name of the file containing renaming, or
5844 dnl disable it altogether.
5845 AC_DEFUN([CF_MANPAGE_RENAMES],
5846 [
5847 AC_MSG_CHECKING(for manpage renaming)
5848
5849 AC_ARG_WITH(manpage-renames,
5850         [  --with-manpage-renames  specify manpage-renaming],
5851         [MANPAGE_RENAMES=$withval],
5852         [MANPAGE_RENAMES=yes])
5853
5854 case ".$MANPAGE_RENAMES" in
5855 (.no)
5856         ;;
5857 (.|.yes)
5858         # Debian 'man' program?
5859         if test -f /etc/debian_version ; then
5860                 MANPAGE_RENAMES=man/man_db.renames
5861         else
5862                 MANPAGE_RENAMES=no
5863         fi
5864         ;;
5865 esac
5866
5867 if test "$MANPAGE_RENAMES" = man/man_db.renames ; then
5868         MANPAGE_RENAMES=`pwd`/$MANPAGE_RENAMES
5869 elif test "$MANPAGE_RENAMES" = no ; then
5870         :
5871 elif test ! -f "$MANPAGE_RENAMES" ; then
5872         AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
5873 fi
5874
5875 AC_MSG_RESULT($MANPAGE_RENAMES)
5876 AC_SUBST(MANPAGE_RENAMES)
5877 ])dnl
5878 dnl ---------------------------------------------------------------------------
5879 dnl CF_MANPAGE_SYMLINKS version: 7 updated: 2023/01/21 16:37:17
5880 dnl -------------------
5881 dnl Some people expect each tool to make all aliases for manpages in the
5882 dnl man-directory.  This accommodates the older, less-capable implementations
5883 dnl of 'man', and is optional.
5884 AC_DEFUN([CF_MANPAGE_SYMLINKS],
5885 [
5886 AC_MSG_CHECKING(if manpage aliases will be installed)
5887
5888 AC_ARG_WITH(manpage-aliases,
5889         [  --with-manpage-aliases  specify manpage-aliases using .so],
5890         [MANPAGE_ALIASES=$withval],
5891         [MANPAGE_ALIASES=yes])
5892
5893 AC_MSG_RESULT($MANPAGE_ALIASES)
5894
5895 case "x$LN_S" in
5896 (xln*)
5897         cf_use_symlinks=yes
5898         ;;
5899 (*)
5900         cf_use_symlinks=no
5901         ;;
5902 esac
5903
5904 MANPAGE_SYMLINKS=no
5905 if test "$MANPAGE_ALIASES" = yes ; then
5906 AC_MSG_CHECKING(if manpage symlinks should be used)
5907
5908 AC_ARG_WITH(manpage-symlinks,
5909         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
5910         [MANPAGE_SYMLINKS=$withval],
5911         [MANPAGE_SYMLINKS=$cf_use_symlinks])
5912
5913 if test "$cf_use_symlinks" = no; then
5914 if test "$MANPAGE_SYMLINKS" = yes ; then
5915         AC_MSG_WARN(cannot make symlinks, will use .so files)
5916         MANPAGE_SYMLINKS=no
5917 fi
5918 fi
5919
5920 AC_MSG_RESULT($MANPAGE_SYMLINKS)
5921 fi
5922
5923 ])dnl
5924 dnl ---------------------------------------------------------------------------
5925 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
5926 dnl --------------
5927 dnl This option causes manpages to be run through tbl(1) to generate tables
5928 dnl correctly.
5929 AC_DEFUN([CF_MANPAGE_TBL],
5930 [
5931 AC_MSG_CHECKING(for manpage tbl)
5932
5933 AC_ARG_WITH(manpage-tbl,
5934         [  --with-manpage-tbl      specify manpage processing with tbl],
5935         [MANPAGE_TBL=$withval],
5936         [MANPAGE_TBL=no])
5937
5938 AC_MSG_RESULT($MANPAGE_TBL)
5939 ])dnl
5940 dnl ---------------------------------------------------------------------------
5941 dnl CF_MAN_PAGES version: 58 updated: 2023/07/28 20:13:29
5942 dnl ------------
5943 dnl Try to determine if the man-pages on the system are compressed, and if
5944 dnl so, what format is used.  Use this information to construct a script that
5945 dnl will install man-pages.
5946 AC_DEFUN([CF_MAN_PAGES],
5947 [
5948 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
5949 CF_MANPAGE_FORMAT
5950 CF_MANPAGE_RENAMES
5951 CF_MANPAGE_SYMLINKS
5952 CF_MANPAGE_TBL
5953
5954 if test "$prefix" = "NONE" ; then
5955         cf_prefix="$ac_default_prefix"
5956 else
5957         cf_prefix="$prefix"
5958 fi
5959
5960 test ! -d man && mkdir man
5961
5962 cf_edit_man=./edit_man.sh
5963 cf_man_alias=`pwd`/man_alias.sed
5964
5965 cat >$cf_edit_man <<CF_EOF
5966 #! $SHELL
5967 # this script is generated by the configure-script CF_MAN_PAGES macro.
5968
5969 prefix="$cf_prefix"
5970 datarootdir="$datarootdir"
5971 datadir="$datadir"
5972
5973 NCURSES_MAJOR="$NCURSES_MAJOR"
5974 NCURSES_MINOR="$NCURSES_MINOR"
5975 NCURSES_PATCH="$NCURSES_PATCH"
5976
5977 NCURSES_OSPEED="$NCURSES_OSPEED"
5978 TERMINFO="$TERMINFO"
5979 TERMINFO_DIRS="$TERMINFO_DIRS"
5980
5981 INSTALL="$INSTALL"
5982 INSTALL_DATA="$INSTALL_DATA"
5983
5984 transform="$program_transform_name"
5985
5986 TMP=\${TMPDIR:=/tmp}/man\$\$
5987 trap "rm -f \$TMP; exit 1" 1 2 3 15
5988 trap "rm -f \$TMP" 0
5989
5990 form=\[$]1
5991 shift || exit 1
5992
5993 verb=\[$]1
5994 shift || exit 1
5995
5996 mandir=\[$]1
5997 shift || exit 1
5998
5999 srcdir=\[$]1
6000 top_srcdir=\[$]srcdir/..
6001 shift || exit 1
6002
6003 if test "\$form" = normal ; then
6004         if test "$cf_manpage_format" = yes ; then
6005         if test "$cf_manpage_inboth" = no ; then
6006                 $SHELL "\[$]0" format "\$verb" "\$mandir" "\$srcdir" "\[$]@"
6007                 exit $?
6008         fi
6009         fi
6010         cf_subdir=\$mandir/man
6011         cf_tables=$MANPAGE_TBL
6012 else
6013         cf_subdir=\$mandir/cat
6014         cf_tables=yes
6015 fi
6016
6017 # process the list of source-files
6018 for i in "\[$]@" ; do
6019 case \$i in
6020 (*.orig|*.rej) ;;
6021 (*.[[0-9]]*)
6022         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
6023         if test "\$verb" = installing ; then
6024         if test ! -d "\$cf_subdir\${section}" ; then
6025                 mkdir -p "\$cf_subdir\$section"
6026         fi
6027         fi
6028
6029         # replace variables in man page
6030         if test ! -f "$cf_man_alias" ; then
6031 cat >>$cf_man_alias <<-CF_EOF2
6032                 s,@DATADIR@,\$datadir,g
6033                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
6034                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
6035                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
6036                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
6037                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
6038                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
6039 CF_EOF
6040         ifelse($1,,,[
6041         for cf_name in $1
6042         do
6043                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6044                 cf_name=`echo "$cf_name" | sed "$program_transform_name"`
6045 cat >>$cf_edit_man <<-CF_EOF
6046                 s,@$cf_NAME@,$cf_name,g
6047 CF_EOF
6048         done
6049         ])
6050 cat >>$cf_edit_man <<CF_EOF
6051 CF_EOF2
6052                 echo "...made $cf_man_alias"
6053         fi
6054
6055         aliases=
6056         cf_source=\`basename "\$i"\`
6057         cf_full_alias=\$cf_source
6058         test ! -f "\$cf_full_alias" && cf_full_alias="\$srcdir/\$cf_full_alias"
6059         if test ! -f "\$cf_full_alias" ; then
6060                 echo ".. skipped \$cf_source"
6061                 continue
6062         fi
6063 CF_EOF
6064
6065 if test "$MANPAGE_ALIASES" != no ; then
6066 cat >>$cf_edit_man <<CF_EOF
6067         nCurses=ignore.3x
6068         cf_part_alias=\`echo \$cf_full_alias| sed -e 's,^.*/,,'\`
6069         test "$with_curses_h" = yes && nCurses=ncurses.3x
6070         aliases=\`sed -f "\$top_srcdir/man/manlinks.sed" "\$cf_full_alias" |sed -f "$cf_man_alias" | sort -u; test "\$cf_part_alias" = "\$nCurses" && echo curses\`
6071 CF_EOF
6072 fi
6073
6074 if test "$MANPAGE_RENAMES" = no ; then
6075 cat >>$cf_edit_man <<CF_EOF
6076         # perform program transformations for section 1 man pages
6077         if test \$section = 1 ; then
6078                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
6079         else
6080                 cf_target=\$cf_subdir\${section}/\$cf_source
6081         fi
6082 CF_EOF
6083 else
6084 cat >>$cf_edit_man <<CF_EOF
6085         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
6086         if test -z "\$cf_target" ; then
6087                 echo "? missing rename for \$cf_source"
6088                 cf_target="\$cf_source"
6089         fi
6090         cf_target="\$cf_subdir\${section}/\${cf_target}"
6091
6092 CF_EOF
6093 fi
6094
6095 cat >>$cf_edit_man <<CF_EOF
6096         sed     -f "$cf_man_alias" \\
6097 CF_EOF
6098
6099 if test "$MANPAGE_RENAMES" != no ; then
6100 cat >>$cf_edit_man <<CF_EOF
6101                 < "\$i" | sed -f `pwd`/edit_man.sed >\$TMP
6102 CF_EOF
6103 else
6104 cat >>$cf_edit_man <<CF_EOF
6105                 < "\$i" >\$TMP
6106 CF_EOF
6107 fi
6108
6109 cat >>$cf_edit_man <<CF_EOF
6110 if test \$cf_tables = yes ; then
6111         tbl \$TMP >\$TMP.out
6112         mv \$TMP.out \$TMP
6113 fi
6114 CF_EOF
6115
6116 if test "$with_overwrite" != yes ; then
6117 cat >>$cf_edit_man <<CF_EOF
6118         sed -e "/\\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
6119         mv \$TMP.out \$TMP
6120 CF_EOF
6121 fi
6122
6123 if test "$with_curses_h" != yes ; then
6124 cat >>$cf_edit_man <<CF_EOF
6125         sed -e "/\\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
6126         mv \$TMP.out \$TMP
6127 CF_EOF
6128 fi
6129
6130 cat >>$cf_edit_man <<CF_EOF
6131         if test "\$form" = format ; then
6132                 nroff -man \$TMP >\$TMP.out
6133                 mv \$TMP.out \$TMP
6134         fi
6135 CF_EOF
6136
6137 if test -n "$cf_manpage_compress" ; then
6138 cat >>$cf_edit_man <<CF_EOF
6139         if test "\$verb" = installing ; then
6140         if ( "$cf_manpage_compress" -f \$TMP )
6141         then
6142                 mv \$TMP.$cf_manpage_so_strip \$TMP
6143         fi
6144         fi
6145         cf_target="\$cf_target.$cf_manpage_so_strip"
6146 CF_EOF
6147 fi
6148
6149 case "$MANPAGE_FORMAT" in
6150 (*BSDI*)
6151 cat >>$cf_edit_man <<CF_EOF
6152         if test "\$form" = format ; then
6153                 # BSDI installs only .0 suffixes in the cat directories
6154                 cf_target="\`echo \$cf_target|sed -e 's/\\.[[1-9]]\\+[[a-z]]*/.0/'\`"
6155         fi
6156 CF_EOF
6157   ;;
6158 esac
6159
6160 cat >>$cf_edit_man <<CF_EOF
6161         suffix=\`basename "\$cf_target" | sed -e 's%^[[^.]]*%%'\`
6162         extra_suffix=
6163         if test -n "$EXTRA_SUFFIX" ; then
6164                 case \$cf_target in
6165                 (*${EXTRA_SUFFIX}\$suffix)
6166                         extra_suffix="$EXTRA_SUFFIX"
6167                         ;;
6168                 esac
6169         fi
6170         if test "\$verb" = installing ; then
6171                 echo "\$verb \$cf_target"
6172                 \$INSTALL_DATA \$TMP "\$cf_target"
6173                 test -d "\$cf_subdir\${section}" &&
6174                 test -n "\$aliases" && (
6175                         cd "\$cf_subdir\${section}" && (
6176                                 cf_source=\`echo "\$cf_target" |sed -e 's%^.*/\\([[^/]][[^/]]*/[[^/]][[^/]]*$\\)%\\1%'\`
6177                                 test -n "$cf_manpage_so_strip" && cf_source=\`echo "\$cf_source" |sed -e 's%\\.$cf_manpage_so_strip\$%%'\`
6178                                 cf_target=\`basename "\$cf_target"\`
6179                                 for cf_alias in \$aliases
6180                                 do
6181                                         if test "\$section" = 1 ; then
6182                                                 cf_alias=\`echo "\$cf_alias" |sed "\${transform}"\`
6183                                         fi
6184                                         cf_alias="\${cf_alias}\${extra_suffix}"
6185
6186                                         if test "$MANPAGE_SYMLINKS" = yes ; then
6187                                                 if test -f "\$cf_alias\${suffix}" ; then
6188                                                         if ( cmp -s "\$cf_target" "\$cf_alias\${suffix}" )
6189                                                         then
6190                                                                 continue
6191                                                         fi
6192                                                 fi
6193                                                 echo ".. \$verb alias \$cf_alias\${suffix}"
6194 CF_EOF
6195 case "x$LN_S" in
6196 (*-f)
6197 cat >>$cf_edit_man <<CF_EOF
6198                                                 $LN_S "\$cf_target" "\$cf_alias\${suffix}"
6199 CF_EOF
6200         ;;
6201 (*)
6202 cat >>$cf_edit_man <<CF_EOF
6203                                                 rm -f "\$cf_alias\${suffix}"
6204                                                 $LN_S "\$cf_target" "\$cf_alias\${suffix}"
6205 CF_EOF
6206         ;;
6207 esac
6208 cat >>$cf_edit_man <<CF_EOF
6209                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
6210                                                 echo ".so \$cf_source" >\$TMP
6211 CF_EOF
6212 if test -n "$cf_manpage_compress" ; then
6213 cat >>$cf_edit_man <<CF_EOF
6214                                                 if test -n "$cf_manpage_so_strip" ; then
6215                                                         "$cf_manpage_compress" -f \$TMP
6216                                                         mv \$TMP.$cf_manpage_so_strip \$TMP
6217                                                 fi
6218 CF_EOF
6219 fi
6220 cat >>$cf_edit_man <<CF_EOF
6221                                                 echo ".. \$verb alias \$cf_alias\${suffix}"
6222                                                 rm -f "\$cf_alias\${suffix}"
6223                                                 \$INSTALL_DATA \$TMP "\$cf_alias\${suffix}"
6224                                         fi
6225                                 done
6226                         )
6227                 )
6228         elif test "\$verb" = removing ; then
6229                 test -f "\$cf_target" && (
6230                         echo "\$verb \$cf_target"
6231                         rm -f "\$cf_target"
6232                 )
6233                 test -d "\$cf_subdir\${section}" &&
6234                 test -n "\$aliases" && (
6235                         cd "\$cf_subdir\${section}" && (
6236                                 for cf_alias in \$aliases
6237                                 do
6238                                         if test "\$section" = 1 ; then
6239                                                 cf_alias=\`echo "\$cf_alias" |sed "\${transform}"\`
6240                                         fi
6241                                         cf_alias="\${cf_alias}\${extra_suffix}"
6242
6243                                         echo ".. \$verb alias \$cf_alias\${suffix}"
6244                                         rm -f "\$cf_alias\${suffix}"
6245                                 done
6246                         )
6247                 )
6248         else
6249 #               echo ".hy 0"
6250                 cat \$TMP
6251         fi
6252         ;;
6253 esac
6254 done
6255
6256 if test "$cf_manpage_inboth" = yes ; then
6257 if test "\$form" != format ; then
6258         $SHELL "\[$]0" format "\$verb" "\$mandir" "\$srcdir" "\[$]@"
6259 fi
6260 fi
6261
6262 exit 0
6263 CF_EOF
6264 chmod 755 "$cf_edit_man"
6265
6266 ])dnl
6267 dnl ---------------------------------------------------------------------------
6268 dnl CF_MAP_LIB_BASENAME version: 2 updated: 2021/01/02 17:09:14
6269 dnl -------------------
6270 dnl Convert a default-libname to the actual one used via CF_WITH_LIB_BASENAME.
6271 dnl
6272 dnl $1 = variable to set
6273 dnl $2 = default-libname
6274 AC_DEFUN([CF_MAP_LIB_BASENAME],[
6275 CF_UPPER(cf_map_lib_basename,$2)
6276 eval $1="\$${cf_map_lib_basename}_NAME"
6277 ])dnl
6278 dnl ---------------------------------------------------------------------------
6279 dnl CF_MATH_LIB version: 11 updated: 2022/07/27 19:01:48
6280 dnl -----------
6281 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
6282 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
6283 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
6284 AC_DEFUN([CF_MATH_LIB],
6285 [
6286 AC_CACHE_CHECK(if -lm needed for math functions,
6287         cf_cv_need_libm,[
6288         AC_TRY_LINK([
6289                 #include <stdio.h>
6290                 #include <stdlib.h>
6291                 #include <math.h>
6292         ],
6293         [double x = rand(); printf("result = %g\\n", ]ifelse([$2],,sin(x),$2)[)],
6294         [cf_cv_need_libm=no],
6295         [cf_cv_need_libm=yes])])
6296
6297 if test "$cf_cv_need_libm" = yes
6298 then
6299
6300         cf_save_LIBS="$LIBS"
6301         LIBS="$LIBS -lm"
6302         AC_CACHE_CHECK(if -lm is available for math functions,
6303         cf_cv_have_libm,[
6304         AC_TRY_LINK([
6305                 #include <stdio.h>
6306                 #include <stdlib.h>
6307                 #include <math.h>
6308         ],
6309         [double x = rand(); printf("result = %g\\n", ]ifelse([$2],,sin(x),$2)[)],
6310         [cf_cv_have_libm=yes],
6311         [cf_cv_have_libm=no])])
6312         LIBS="$cf_save_LIBS"
6313
6314         if test "$cf_cv_have_libm" = yes
6315         then
6316                 ifelse($1,,[CF_ADD_LIB(m)],[$1=-lm])
6317         fi
6318 else
6319         cf_cv_have_libm=yes
6320 fi
6321
6322 if test "$cf_cv_have_libm" = yes
6323 then
6324         AC_DEFINE(HAVE_MATH_FUNCS,1,[Define to 1 if math functions are available])
6325 fi
6326 ])
6327 dnl ---------------------------------------------------------------------------
6328 dnl CF_MIXEDCASE_FILENAMES version: 9 updated: 2021/01/01 16:53:59
6329 dnl ----------------------
6330 dnl Check if the file-system supports mixed-case filenames.  If we're able to
6331 dnl create a lowercase name and see it as uppercase, it doesn't support that.
6332 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
6333 [
6334 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
6335 if test "$cross_compiling" = yes ; then
6336         case "$target_alias" in
6337         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*|darwin*)
6338                 cf_cv_mixedcase=no
6339                 ;;
6340         (*)
6341                 cf_cv_mixedcase=yes
6342                 ;;
6343         esac
6344 else
6345         rm -f conftest CONFTEST
6346         echo test >conftest
6347         if test -f CONFTEST ; then
6348                 cf_cv_mixedcase=no
6349         else
6350                 cf_cv_mixedcase=yes
6351         fi
6352         rm -f conftest CONFTEST
6353 fi
6354 ])
6355 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
6356 ])dnl
6357 dnl ---------------------------------------------------------------------------
6358 dnl CF_MKSTEMP version: 13 updated: 2023/12/01 17:22:50
6359 dnl ----------
6360 dnl Check for a working mkstemp.  This creates two files, checks that they are
6361 dnl successfully created and distinct (AmigaOS apparently fails on the last).
6362 AC_DEFUN([CF_MKSTEMP],[
6363 AC_CHECK_HEADERS( \
6364 unistd.h \
6365 )
6366 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
6367 rm -rf ./conftest*
6368 AC_TRY_RUN([
6369 $ac_includes_default
6370
6371 int main(void)
6372 {
6373         static char tmpl[] = "conftestXXXXXX";
6374         char name[2][80];
6375         int n;
6376         int result = 0;
6377         int fd;
6378         struct stat sb;
6379
6380         umask(077);
6381         for (n = 0; n < 2; ++n) {
6382                 strcpy(name[n], tmpl);
6383                 if ((fd = mkstemp(name[n])) >= 0) {
6384                         if (!strcmp(name[n], tmpl)
6385                          || stat(name[n], &sb) != 0
6386                          || (sb.st_mode & S_IFMT) != S_IFREG
6387                          || (sb.st_mode & 077) != 0) {
6388                                 result = 1;
6389                         }
6390                         close(fd);
6391                 }
6392         }
6393         if (result == 0
6394          && !strcmp(name[0], name[1]))
6395                 result = 1;
6396         ${cf_cv_main_return:-return}(result);
6397 }
6398 ],[cf_cv_func_mkstemp=yes
6399 ],[cf_cv_func_mkstemp=no
6400 ],[cf_cv_func_mkstemp=maybe])
6401 ])
6402 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
6403         AC_CHECK_FUNC(mkstemp)
6404 fi
6405 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
6406         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
6407 fi
6408 ])dnl
6409 dnl ---------------------------------------------------------------------------
6410 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
6411 dnl ----------
6412 dnl Write a debug message to config.log, along with the line number in the
6413 dnl configure script.
6414 AC_DEFUN([CF_MSG_LOG],[
6415 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
6416 ])dnl
6417 dnl ---------------------------------------------------------------------------
6418 dnl CF_NCURSES_ABI_6 version: 5 updated: 2023/01/07 16:32:06
6419 dnl ----------------
6420 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
6421 dnl warn about this.
6422 AC_DEFUN([CF_NCURSES_ABI_6],[
6423 if test "${with_abi_version+set}" != set; then
6424         case "$cf_cv_rel_version" in
6425         (5.*)
6426                 cf_cv_rel_version=6.0
6427                 cf_cv_abi_version=6
6428                 cf_cv_abi_default=6
6429                 AC_MSG_WARN(overriding ABI version to $cf_cv_abi_default)
6430                 ;;
6431         esac
6432 fi
6433 ])dnl
6434 dnl ---------------------------------------------------------------------------
6435 dnl CF_NCURSES_WITH_ABI_VERSION version: 3 updated: 2021/01/01 13:31:04
6436 dnl ---------------------------
6437 dnl Allow ncurses's ABI to be overridden.  Generally this happens when a
6438 dnl packager has incremented the ABI past that used in the original package,
6439 dnl and wishes to keep doing this.
6440 dnl
6441 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
6442 dnl symbol.
6443 AC_DEFUN([CF_NCURSES_WITH_ABI_VERSION],[
6444 CF_WITH_ABI_VERSION($1)
6445 if test "x$cf_cv_abi_version" != "x$with_abi_version"
6446 then
6447         case "$cf_cv_rel_version" in
6448         (5.*)
6449                 cf_cv_rel_version=$with_abi_version.0
6450                 ;;
6451         esac
6452 fi
6453 ])dnl
6454 dnl ---------------------------------------------------------------------------
6455 dnl CF_NO_LEAKS_OPTION version: 9 updated: 2021/06/13 19:45:41
6456 dnl ------------------
6457 dnl see CF_WITH_NO_LEAKS
6458 dnl
6459 dnl $1 = option/name
6460 dnl $2 = help-text
6461 dnl $3 = symbol to define if the option is set
6462 dnl $4 = additional actions to take if the option is set
6463 AC_DEFUN([CF_NO_LEAKS_OPTION],[
6464 AC_MSG_CHECKING(if you want to use $1 for testing)
6465 AC_ARG_WITH($1,
6466         [$2],
6467         [case "x$withval" in
6468         (x|xno) ;;
6469         (*)
6470                 : "${with_cflags:=-g}"
6471                 : "${enable_leaks:=no}"
6472                 with_$1=yes
6473                 AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
6474          $4
6475 ])
6476                 ;;
6477         esac],
6478         [with_$1=])
6479 AC_MSG_RESULT(${with_$1:-no})
6480
6481 case ".$with_cflags" in
6482 (.*-g*)
6483         case .$CFLAGS in
6484         (.*-g*)
6485                 ;;
6486         (*)
6487                 CF_ADD_CFLAGS([-g])
6488                 ;;
6489         esac
6490         ;;
6491 esac
6492 ])dnl
6493 dnl ---------------------------------------------------------------------------
6494 dnl CF_NUMBER_SYNTAX version: 3 updated: 2023/05/06 16:14:29
6495 dnl ----------------
6496 dnl Check if the given variable is a positive integer.  Report an error if not.
6497 dnl $1 is the variable
6498 dnl $2 is the message
6499 AC_DEFUN([CF_NUMBER_SYNTAX],[
6500 if test -n "$1" ; then
6501   case `echo "$1" | sed -e 's/^[[0-9]]*$/0/g'` in
6502   (0)
6503         ;;
6504   (*)
6505         AC_MSG_ERROR($2 is not a number: $1)
6506         ;;
6507   esac
6508 else
6509   AC_MSG_ERROR($2 value is empty)
6510 fi
6511 ])dnl
6512 dnl ---------------------------------------------------------------------------
6513 dnl CF_OBJ_SUBDIR version: 8 updated: 2021/01/01 13:31:04
6514 dnl -------------
6515 dnl Compute the object-directory name from the given model name
6516 AC_DEFUN([CF_OBJ_SUBDIR],
6517 [
6518         case $1 in
6519         (libtool) $2='obj_lo'  ;;
6520         (normal)  $2='objects' ;;
6521         (debug)   $2='obj_g' ;;
6522         (profile) $2='obj_p' ;;
6523         (shared)
6524                 case "$cf_cv_system_name" in
6525                 (cygwin|msys)
6526                         $2='objects' ;;
6527                 (*)
6528                         $2='obj_s' ;;
6529                 esac
6530         esac
6531 ])dnl
6532 dnl ---------------------------------------------------------------------------
6533 dnl CF_OUTPUT_MANPAGE_RENAMES version: 2 updated: 2022/10/22 19:12:31
6534 dnl -------------------------
6535 dnl This runs in the output step to config.status, after man_db.renames has
6536 dnl been generated.
6537 AC_DEFUN([CF_OUTPUT_MANPAGE_RENAMES],
6538 [
6539 AC_REQUIRE([CF_MANPAGE_RENAMES])
6540 if test "$MANPAGE_RENAMES" != no ; then
6541         # Construct a sed-script to perform renaming within man-pages
6542         test -n "$verbose" && echo "creating edit_man.sed"
6543         test ! -d man && mkdir man
6544         FGREP="${FGREP-grep -F}" $SHELL "$srcdir/man/make_sed.sh" "$MANPAGE_RENAMES" >./edit_man.sed
6545 fi
6546 ])dnl
6547 dnl ---------------------------------------------------------------------------
6548 dnl CF_PATHSEP version: 8 updated: 2021/01/01 13:31:04
6549 dnl ----------
6550 dnl Provide a value for the $PATH and similar separator (or amend the value
6551 dnl as provided in autoconf 2.5x).
6552 AC_DEFUN([CF_PATHSEP],
6553 [
6554         AC_MSG_CHECKING(for PATH separator)
6555         case "$cf_cv_system_name" in
6556         (os2*)  PATH_SEPARATOR=';'  ;;
6557         (*)     ${PATH_SEPARATOR:=':'}  ;;
6558         esac
6559 ifelse([$1],,,[$1=$PATH_SEPARATOR])
6560         AC_SUBST(PATH_SEPARATOR)
6561         AC_MSG_RESULT($PATH_SEPARATOR)
6562 ])dnl
6563 dnl ---------------------------------------------------------------------------
6564 dnl CF_PATH_PROG version: 12 updated: 2021/01/02 09:31:20
6565 dnl ------------
6566 dnl Check for a given program, defining corresponding symbol.
6567 dnl     $1 = environment variable, which is suffixed by "_PATH" in the #define.
6568 dnl     $2 = program name to find.
6569 dnl     $3 = optional list of additional program names to test.
6570 dnl $4 = $PATH
6571 dnl
6572 dnl If there is more than one token in the result, #define the remaining tokens
6573 dnl to $1_ARGS.  We need this for 'install' in particular.
6574 dnl
6575 dnl FIXME: we should allow this to be overridden by environment variables
6576 dnl
6577 AC_DEFUN([CF_PATH_PROG],[
6578 AC_REQUIRE([CF_PATHSEP])
6579 test -z "[$]$1" && $1="$2"
6580 AC_PATH_PROGS($1,[$]$1 $2 ifelse($3,,,$3),[$]$1, ifelse($4,,,$4))
6581
6582 cf_path_prog=""
6583 cf_path_args=""
6584 IFS="${IFS:-    }"; cf_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR"
6585 for cf_temp in $ac_cv_path_$1
6586 do
6587         if test -z "$cf_path_prog" ; then
6588                 if test "$with_full_paths" = yes ; then
6589                         CF_PATH_SYNTAX(cf_temp,break)
6590                         cf_path_prog="$cf_temp"
6591                 else
6592                         cf_path_prog="`basename "$cf_temp"`"
6593                 fi
6594         elif test -z "$cf_path_args" ; then
6595                 cf_path_args="$cf_temp"
6596         else
6597                 cf_path_args="$cf_path_args $cf_temp"
6598         fi
6599 done
6600 IFS="$cf_save_ifs"
6601
6602 if test -n "$cf_path_prog" ; then
6603         CF_MSG_LOG(defining path for ${cf_path_prog})
6604         AC_DEFINE_UNQUOTED($1_PATH,"$cf_path_prog",Define to pathname $1)
6605         test -n "$cf_path_args" && AC_DEFINE_UNQUOTED($1_ARGS,"$cf_path_args",Define to provide args for $1)
6606 fi
6607 ])dnl
6608 dnl ---------------------------------------------------------------------------
6609 dnl CF_PATH_SYNTAX version: 18 updated: 2020/12/31 18:40:20
6610 dnl --------------
6611 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
6612 dnl begins with one of the prefix/exec_prefix variables, and then again if the
6613 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
6614 dnl delayed evaluation of those symbols.
6615 AC_DEFUN([CF_PATH_SYNTAX],[
6616 if test "x$prefix" != xNONE; then
6617         cf_path_syntax="$prefix"
6618 else
6619         cf_path_syntax="$ac_default_prefix"
6620 fi
6621
6622 case ".[$]$1" in
6623 (.\[$]\(*\)*|.\'*\'*)
6624         ;;
6625 (..|./*|.\\*)
6626         ;;
6627 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
6628         ;;
6629 (.\[$]\{*prefix\}*|.\[$]\{*dir\}*)
6630         eval $1="[$]$1"
6631         case ".[$]$1" in
6632         (.NONE/*)
6633                 $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
6634                 ;;
6635         esac
6636         ;;
6637 (.no|.NONE/*)
6638         $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
6639         ;;
6640 (*)
6641         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
6642         ;;
6643 esac
6644 ])dnl
6645 dnl ---------------------------------------------------------------------------
6646 dnl CF_PKG_CONFIG version: 13 updated: 2023/10/28 11:59:01
6647 dnl -------------
6648 dnl Check for the package-config program, unless disabled by command-line.
6649 dnl
6650 dnl Sets $PKG_CONFIG to the pathname of the pkg-config program.
6651 AC_DEFUN([CF_PKG_CONFIG],
6652 [
6653 AC_MSG_CHECKING(if you want to use pkg-config)
6654 AC_ARG_WITH(pkg-config,
6655         [[  --with-pkg-config[=CMD] enable/disable use of pkg-config and its name CMD]],
6656         [cf_pkg_config=$withval],
6657         [cf_pkg_config=yes])
6658 AC_MSG_RESULT($cf_pkg_config)
6659
6660 case "$cf_pkg_config" in
6661 (no)
6662         PKG_CONFIG=none
6663         ;;
6664 (yes)
6665         CF_ACVERSION_CHECK(2.52,
6666                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
6667                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
6668         ;;
6669 (*)
6670         PKG_CONFIG=$withval
6671         ;;
6672 esac
6673
6674 test -z "$PKG_CONFIG" && PKG_CONFIG=none
6675 if test "$PKG_CONFIG" != none ; then
6676         CF_PATH_SYNTAX(PKG_CONFIG)
6677 elif test "x$cf_pkg_config" != xno ; then
6678         AC_MSG_WARN(pkg-config is not installed)
6679 fi
6680
6681 AC_SUBST(PKG_CONFIG)
6682 ])dnl
6683 dnl ---------------------------------------------------------------------------
6684 dnl CF_POSIX_C_SOURCE version: 12 updated: 2023/02/18 17:41:25
6685 dnl -----------------
6686 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
6687 dnl
6688 dnl     POSIX.1-1990                            _POSIX_SOURCE
6689 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
6690 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
6691 dnl             Bindings Option
6692 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
6693 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
6694 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
6695 dnl
6696 dnl Parameters:
6697 dnl     $1 is the nominal value for _POSIX_C_SOURCE
6698 AC_DEFUN([CF_POSIX_C_SOURCE],
6699 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
6700
6701 if test "$cf_cv_posix_visible" = no; then
6702
6703 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
6704
6705 cf_save_CFLAGS="$CFLAGS"
6706 cf_save_CPPFLAGS="$CPPFLAGS"
6707
6708 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
6709 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
6710
6711 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
6712         CF_MSG_LOG(if the symbol is already defined go no further)
6713         AC_TRY_COMPILE([#include <sys/types.h>],[
6714 #ifndef _POSIX_C_SOURCE
6715 #error _POSIX_C_SOURCE is not defined
6716 #endif],
6717         [cf_cv_posix_c_source=no],
6718         [cf_want_posix_source=no
6719          case .$cf_POSIX_C_SOURCE in
6720          (.[[12]]??*)
6721                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
6722                 ;;
6723          (.2)
6724                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
6725                 cf_want_posix_source=yes
6726                 ;;
6727          (.*)
6728                 cf_want_posix_source=yes
6729                 ;;
6730          esac
6731          if test "$cf_want_posix_source" = yes ; then
6732                 AC_TRY_COMPILE([#include <sys/types.h>],[
6733 #ifdef _POSIX_SOURCE
6734 #error _POSIX_SOURCE is defined
6735 #endif],[],
6736                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
6737          fi
6738          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
6739          CFLAGS="$cf_trim_CFLAGS"
6740          CPPFLAGS="$cf_trim_CPPFLAGS"
6741          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
6742          CF_MSG_LOG(if the second compile does not leave our definition intact error)
6743          AC_TRY_COMPILE([#include <sys/types.h>],[
6744 #ifndef _POSIX_C_SOURCE
6745 #error _POSIX_C_SOURCE is not defined
6746 #endif],,
6747          [cf_cv_posix_c_source=no])
6748          CFLAGS="$cf_save_CFLAGS"
6749          CPPFLAGS="$cf_save_CPPFLAGS"
6750         ])
6751 ])
6752
6753 if test "$cf_cv_posix_c_source" != no ; then
6754         CFLAGS="$cf_trim_CFLAGS"
6755         CPPFLAGS="$cf_trim_CPPFLAGS"
6756         CF_ADD_CFLAGS($cf_cv_posix_c_source)
6757 fi
6758
6759 fi # cf_cv_posix_visible
6760
6761 ])dnl
6762 dnl ---------------------------------------------------------------------------
6763 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
6764 dnl ----------------
6765 dnl POSIX documents test-macros which an application may set before any system
6766 dnl headers are included to make features available.
6767 dnl
6768 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
6769 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
6770 dnl recent features visible in the system header files unless the application
6771 dnl overrides the corresponding test-macros.  Doing that introduces portability
6772 dnl problems.
6773 dnl
6774 dnl This macro makes a special check for the symbols used for this, to avoid a
6775 dnl conflicting definition.
6776 AC_DEFUN([CF_POSIX_VISIBLE],
6777 [
6778 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
6779 AC_TRY_COMPILE([#include <stdio.h>],[
6780 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
6781         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
6782         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
6783         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
6784 #error conflicting symbols found
6785 #endif
6786 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
6787 ])
6788 ])dnl
6789 dnl ---------------------------------------------------------------------------
6790 dnl CF_PREDEFINE version: 3 updated: 2023/02/18 17:41:25
6791 dnl ------------
6792 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
6793 dnl
6794 dnl $1 = symbol to test
6795 dnl $2 = value (if any) to use for a predefinition
6796 AC_DEFUN([CF_PREDEFINE],
6797 [
6798 AC_MSG_CHECKING(if we must define $1)
6799 AC_TRY_COMPILE([#include <sys/types.h>
6800 ],[
6801 #ifndef $1
6802 #error $1 is not defined
6803 #endif],[cf_result=no],[cf_result=yes])
6804 AC_MSG_RESULT($cf_result)
6805
6806 if test "$cf_result" = yes ; then
6807         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
6808 elif test "x$2" != "x" ; then
6809         AC_MSG_CHECKING(checking for compatible value versus $2)
6810         AC_TRY_COMPILE([#include <sys/types.h>
6811 ],[
6812 #if $1-$2 < 0
6813 #error $1-$2 is negative
6814 #endif],[cf_result=yes],[cf_result=no])
6815         AC_MSG_RESULT($cf_result)
6816         if test "$cf_result" = no ; then
6817                 # perhaps we can override it - try...
6818                 CPPFLAGS="$CPPFLAGS -D$1=$2"
6819         fi
6820 fi
6821 ])dnl
6822 dnl ---------------------------------------------------------------------------
6823 dnl CF_PRG_RULES version: 2 updated: 2021/01/01 13:31:04
6824 dnl ------------
6825 dnl Append definitions and rules for the given programs to the subdirectory
6826 dnl Makefiles, and the recursion rule for the top-level Makefile.
6827 dnl
6828 dnl parameters
6829 dnl     $1 = script to run
6830 dnl     $2 = list of subdirectories
6831 dnl
6832 dnl variables
6833 dnl     $AWK
6834 AC_DEFUN([CF_PRG_RULES],
6835 [
6836 for cf_dir in $2
6837 do
6838         if test ! -d "$srcdir/$cf_dir" ; then
6839                 continue
6840         elif test -f "$srcdir/$cf_dir/programs" ; then
6841                 $AWK -f $1 "$srcdir/$cf_dir/programs" >>$cf_dir/Makefile
6842         fi
6843 done
6844
6845 ])dnl
6846 dnl ---------------------------------------------------------------------------
6847 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
6848 dnl ----------
6849 dnl Check for archiver "ar".
6850 AC_DEFUN([CF_PROG_AR],[
6851 AC_CHECK_TOOL(AR, ar, ar)
6852 ])
6853 dnl ---------------------------------------------------------------------------
6854 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
6855 dnl -----------
6856 dnl Check for awk, ensure that the check found something.
6857 AC_DEFUN([CF_PROG_AWK],
6858 [
6859 AC_PROG_AWK
6860 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
6861 ])dnl
6862 dnl ---------------------------------------------------------------------------
6863 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
6864 dnl ----------
6865 dnl standard check for CC, plus followup sanity checks
6866 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
6867 AC_DEFUN([CF_PROG_CC],[
6868 CF_ACVERSION_CHECK(2.53,
6869         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
6870          AC_REQUIRE([AC_PROG_CC])],
6871         [])
6872 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
6873 CF_GCC_VERSION
6874 CF_ACVERSION_CHECK(2.52,
6875         [AC_PROG_CC_STDC],
6876         [CF_ANSI_CC_REQD])
6877 CF_CC_ENV_FLAGS
6878 ])dnl
6879 dnl ---------------------------------------------------------------------------
6880 dnl CF_PROG_CC_C_O version: 6 updated: 2021/01/01 13:31:04
6881 dnl --------------
6882 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
6883 dnl the output file can be renamed, and allows for a shell variable that can
6884 dnl be used later.  The parameter is either CC or CXX.  The result is the
6885 dnl cache variable:
6886 dnl     $cf_cv_prog_CC_c_o
6887 dnl     $cf_cv_prog_CXX_c_o
6888 dnl
6889 dnl $1 = compiler
6890 dnl $2 = compiler options, if any
6891 AC_DEFUN([CF_PROG_CC_C_O],
6892 [AC_REQUIRE([AC_PROG_CC])dnl
6893 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
6894 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
6895 [
6896 cat > conftest.$ac_ext <<CF_EOF
6897 int main(void)
6898 {
6899         ${cf_cv_main_return:-return}(0);
6900 }
6901 CF_EOF
6902 # We do the test twice because some compilers refuse to overwrite an
6903 # existing .o file with -o, though they will create one.
6904 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
6905 if AC_TRY_EVAL(ac_try) &&
6906   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
6907 then
6908   eval cf_cv_prog_$1_c_o=yes
6909 else
6910   eval cf_cv_prog_$1_c_o=no
6911 fi
6912 rm -rf ./conftest*
6913 ])dnl
6914 if test "$cf_cv_prog_$1_c_o" = yes; then
6915   AC_MSG_RESULT([yes])
6916 else
6917   AC_MSG_RESULT([no])
6918 fi
6919 ])dnl
6920 dnl ---------------------------------------------------------------------------
6921 dnl CF_PROG_GNAT version: 12 updated: 2021/01/02 17:09:14
6922 dnl ------------
6923 dnl Check for gnat/gnatmake/etc, ensure that the toolset is complete.
6924 AC_DEFUN([CF_PROG_GNAT],[
6925 for cf_prog_gnat in gnat gnatmake gprconfig gprbuild
6926 do
6927         CF_UPPER(cf_upper_prog_gnat,${cf_prog_gnat})
6928
6929         unset ac_cv_path_cf_TEMP_gnat
6930         unset cf_TEMP_gnat
6931         AC_PATH_PROG(cf_TEMP_gnat,$cf_prog_gnat,no)
6932         eval "cf_cv_PATH_$cf_upper_prog_gnat=[$]ac_cv_path_cf_TEMP_gnat"
6933
6934         if test "x$cf_TEMP_gnat" != xno; then
6935                 unset cf_cv_gnat_version
6936                 unset cf_TEMP_gnat
6937                 CF_GNAT_VERSION(cf_TEMP_gnat,$cf_prog_gnat)
6938         fi
6939         eval "cf_cv_VERSION_$cf_upper_prog_gnat=[$]cf_TEMP_gnat"
6940
6941         unset cf_TEMP_gnat
6942         unset cf_cv_gnat_version
6943         unset ac_cv_path_cf_TEMP_gnat
6944 done
6945
6946 if test "x$cf_cv_VERSION_GNATMAKE" = "xno"; then
6947         cf_ada_make=
6948         cf_cv_prog_gnat_correct=no
6949 else
6950         cf_ada_make=gnatmake
6951         if test "x$cf_cv_VERSION_GPRCONFIG" = "xno"; then
6952                 # gprconfig is newer than gnatmake; we can continue...
6953                 cf_ada_config="##"
6954         else
6955                 rm -rf ./conftest* ./*~conftest*
6956                 if mkdir conftest.src
6957                 then
6958                         cf_ada_config=""
6959                         cd conftest.src
6960                         for cf_gprconfig in Ada C
6961                         do
6962                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
6963                                 if test "$cf_gprconfig" = C
6964                                 then
6965                                         for cf_gprconfig_param in \
6966                                                 "$cf_gprconfig,,,,GNATGCC" \
6967                                                 "$cf_gprconfig,,,,GCC" \
6968                                                 "$cf_gprconfig"
6969                                         do
6970                                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6971                                                 test -n "$cf_gprconfig_value" && break
6972                                         done
6973                                 else
6974                                         cf_gprconfig_param=$cf_gprconfig
6975                                         cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6976                                 fi
6977                                 if test -n "$cf_gprconfig_value"
6978                                 then
6979                                         eval "cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value"
6980                                         AC_MSG_RESULT($cf_gprconfig_value)
6981                                 else
6982                                         AC_MSG_RESULT(missing)
6983                                         cf_ada_config="#"
6984                                         break
6985                                 fi
6986                         done
6987                         cd ..
6988                         rm -rf ./conftest* ./*~conftest*
6989                 fi
6990         fi
6991         if test "x$cf_ada_config" != "x#"
6992         then
6993                 CF_GNAT_VERSION
6994                 CF_CHECK_GNAT_VERSION
6995                 AC_CHECK_PROG(M4_exists, m4, yes, no)
6996                 if test "$ac_cv_prog_M4_exists" = no; then
6997                         cf_cv_prog_gnat_correct=no
6998                         AC_MSG_WARN(Ada95 binding required program m4 not found. Ada95 binding disabled)
6999                 fi
7000                 if test "$cf_cv_prog_gnat_correct" = yes; then
7001                         AC_MSG_CHECKING(if GNAT works)
7002                         CF_GNAT_TRY_RUN([procedure conftest;],
7003 [with Text_IO;
7004 with GNAT.OS_Lib;
7005 procedure conftest is
7006 begin
7007    Text_IO.Put ("Hello World");
7008    Text_IO.New_Line;
7009    GNAT.OS_Lib.OS_Exit (0);
7010 end conftest;],
7011 [cf_cv_prog_gnat_correct=yes],
7012 [cf_cv_prog_gnat_correct=no])
7013                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
7014                 fi
7015         else
7016                 cf_cv_prog_gnat_correct=no
7017         fi
7018 fi
7019
7020 AC_SUBST(cf_ada_make)
7021 AC_SUBST(cf_ada_config)
7022 AC_SUBST(cf_ada_config_Ada)
7023 AC_SUBST(cf_ada_config_C)
7024 ])dnl
7025 dnl ---------------------------------------------------------------------------
7026 dnl CF_PROG_INSTALL version: 10 updated: 2021/01/04 19:33:05
7027 dnl ---------------
7028 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
7029 dnl misc/tabset install won't work properly.  Usually this happens only when
7030 dnl using the fallback mkinstalldirs script
7031 AC_DEFUN([CF_PROG_INSTALL],
7032 [AC_PROG_INSTALL
7033 case $INSTALL in
7034 (/*)
7035         ;;
7036 (*)
7037         CF_DIRNAME(cf_dir,$INSTALL)
7038         test -z "$cf_dir" && cf_dir=.
7039         INSTALL="`cd \"$cf_dir\" && pwd`"/"`echo "$INSTALL" | sed -e 's%^.*/%%'`"
7040         ;;
7041 esac
7042 ])dnl
7043 dnl ---------------------------------------------------------------------------
7044 dnl CF_PROG_LDCONFIG version: 5 updated: 2015/04/18 08:56:57
7045 dnl ----------------
7046 dnl Check for ldconfig, needed to fixup shared libraries that would be built
7047 dnl and then used in the install.
7048 AC_DEFUN([CF_PROG_LDCONFIG],[
7049 if test "$cross_compiling" = yes ; then
7050         LDCONFIG=:
7051 else
7052         case "$cf_cv_system_name" in
7053         (dragonfly*|mirbsd*|freebsd*)
7054                 test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
7055                 ;;
7056         (*) LDPATH=$PATH:/sbin:/usr/sbin
7057                 AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
7058                 ;;
7059         esac
7060 fi
7061 AC_SUBST(LDCONFIG)
7062 ])dnl
7063 dnl ---------------------------------------------------------------------------
7064 dnl CF_PROG_LINT version: 5 updated: 2022/08/20 15:44:13
7065 dnl ------------
7066 AC_DEFUN([CF_PROG_LINT],
7067 [
7068 AC_CHECK_PROGS(LINT, lint cppcheck splint)
7069 case "x$LINT" in
7070 (xcppcheck|x*/cppcheck)
7071         test -z "$LINT_OPTS" && LINT_OPTS="--enable=all"
7072         ;;
7073 esac
7074 AC_SUBST(LINT_OPTS)
7075 AC_SUBST(LINT_LIBS)
7076 ])dnl
7077 dnl ---------------------------------------------------------------------------
7078 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
7079 dnl ------------
7080 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
7081 dnl option if it is supported.
7082 AC_DEFUN([CF_PROG_LN_S],[
7083 AC_PROG_LN_S
7084 AC_MSG_CHECKING(if $LN_S -f options work)
7085
7086 rm -f conf$$.src conf$$dst
7087 echo >conf$$.dst
7088 echo first >conf$$.src
7089 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
7090         cf_prog_ln_sf=yes
7091 else
7092         cf_prog_ln_sf=no
7093 fi
7094 rm -f conf$$.dst conf$$src
7095 AC_MSG_RESULT($cf_prog_ln_sf)
7096
7097 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
7098 ])dnl
7099 dnl ---------------------------------------------------------------------------
7100 dnl CF_REGEX version: 18 updated: 2021/01/01 16:53:59
7101 dnl --------
7102 dnl Attempt to determine if we've got one of the flavors of regular-expression
7103 dnl code that we can support.
7104 AC_DEFUN([CF_REGEX],
7105 [
7106
7107 cf_regex_func=no
7108 cf_regex_libs=
7109 case "$host_os" in
7110 (mingw*)
7111         # -lsystre -ltre -lintl -liconv
7112         AC_CHECK_LIB(systre,regcomp,[
7113                 AC_CHECK_LIB(iconv,libiconv_open,[CF_ADD_LIB(iconv)])
7114                 AC_CHECK_LIB(intl,libintl_gettext,[CF_ADD_LIB(intl)])
7115                 AC_CHECK_LIB(tre,tre_regcomp,[CF_ADD_LIB(tre)])
7116                 CF_ADD_LIB(systre)
7117                 cf_regex_func=regcomp
7118         ],[
7119                 AC_CHECK_LIB(gnurx,regcomp,[
7120                         CF_ADD_LIB(gnurx)
7121                         cf_regex_func=regcomp])
7122         ])
7123         ;;
7124 (*)
7125         cf_regex_libs="regex re"
7126         AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
7127                 for cf_regex_lib in $cf_regex_libs
7128                 do
7129                         AC_CHECK_LIB($cf_regex_lib,regcomp,[
7130                                         CF_ADD_LIB($cf_regex_lib)
7131                                         cf_regex_func=regcomp
7132                                         break])
7133                 done
7134         ])
7135         ;;
7136 esac
7137
7138 if test "$cf_regex_func" = no ; then
7139         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
7140                 AC_CHECK_LIB(gen,compile,[
7141                                 CF_ADD_LIB(gen)
7142                                 cf_regex_func=compile])])
7143 fi
7144
7145 if test "$cf_regex_func" = no ; then
7146         AC_MSG_WARN(cannot find regular expression library)
7147 fi
7148
7149 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
7150
7151 cf_cv_regex_hdrs=no
7152 case "$cf_regex_func" in
7153 (compile)
7154         for cf_regex_hdr in regexp.h regexpr.h
7155         do
7156                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
7157                         char *p = compile("", "", "", 0);
7158                         int x = step("", "");
7159                         (void)p;
7160                         (void)x;
7161                 ],[
7162                         cf_cv_regex_hdrs=$cf_regex_hdr
7163                         break
7164                 ])
7165         done
7166         ;;
7167 (*)
7168         for cf_regex_hdr in regex.h
7169         do
7170                 AC_TRY_LINK([#include <sys/types.h>
7171 #include <$cf_regex_hdr>],[
7172                         regex_t *p = 0;
7173                         int x = regcomp(p, "", 0);
7174                         int y = regexec(p, "", 0, 0, 0);
7175                         (void)x;
7176                         (void)y;
7177                         regfree(p);
7178                 ],[
7179                         cf_cv_regex_hdrs=$cf_regex_hdr
7180                         break
7181                 ])
7182         done
7183         ;;
7184 esac
7185
7186 ])
7187
7188 case "$cf_cv_regex_hdrs" in
7189         (no)            AC_MSG_WARN(no regular expression header found) ;;
7190         (regex.h)       AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;;
7191         (regexp.h)      AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;;
7192         (regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
7193 esac
7194 ])dnl
7195 dnl ---------------------------------------------------------------------------
7196 dnl CF_REMOVE_CFLAGS version: 3 updated: 2021/09/05 17:25:40
7197 dnl ----------------
7198 dnl Remove a given option from CFLAGS/CPPFLAGS
7199 dnl $1 = option to remove
7200 dnl $2 = variable to update
7201 dnl $3 = nonempty to allow verbose message
7202 define([CF_REMOVE_CFLAGS],
7203 [
7204 cf_tmp_cflag=`echo "x$1" | sed -e 's/^.//' -e 's/=.*//'`
7205 while true
7206 do
7207         cf_old_cflag=`echo "x[$]$2" | sed -e 's/^.//' -e 's/[[  ]][[    ]]*-/ -/g' -e "s%$cf_tmp_cflag\\(=[[^   ]][[^   ]]*\\)\?%%" -e 's/^[[   ]]*//' -e 's%[[ ]][[ ]]*-D% -D%g' -e 's%[[ ]][[ ]]*-I% -I%g'`
7208         test "[$]$2" != "$cf_old_cflag" || break
7209         ifelse([$3],,,[CF_VERBOSE(removing old option $1 from $2)])
7210         $2="$cf_old_cflag"
7211 done
7212 ])dnl
7213 dnl ---------------------------------------------------------------------------
7214 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
7215 dnl ----------------
7216 dnl Remove all -U and -D options that refer to the given symbol from a list
7217 dnl of C compiler options.  This works around the problem that not all
7218 dnl compilers process -U and -D options from left-to-right, so a -U option
7219 dnl cannot be used to cancel the effect of a preceding -D option.
7220 dnl
7221 dnl $1 = target (which could be the same as the source variable)
7222 dnl $2 = source (including '$')
7223 dnl $3 = symbol to remove
7224 define([CF_REMOVE_DEFINE],
7225 [
7226 $1=`echo "$2" | \
7227         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
7228                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
7229 ])dnl
7230 dnl ---------------------------------------------------------------------------
7231 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
7232 dnl -------------
7233 dnl Remove the given library from the symbol
7234 dnl
7235 dnl $1 = target (which could be the same as the source variable)
7236 dnl $2 = source (including '$')
7237 dnl $3 = library to remove
7238 define([CF_REMOVE_LIB],
7239 [
7240 # remove $3 library from $2
7241 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
7242 ])dnl
7243 dnl ---------------------------------------------------------------------------
7244 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
7245 dnl ---------------------
7246 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
7247 dnl $1 = name of current macro
7248 define([CF_RESTORE_XTRA_FLAGS],
7249 [
7250 LIBS="$cf_save_LIBS_$1"
7251 CFLAGS="$cf_save_CFLAGS_$1"
7252 CPPFLAGS="$cf_save_CPPFLAGS_$1"
7253 ])dnl
7254 dnl ---------------------------------------------------------------------------
7255 dnl CF_RPATH_HACK version: 13 updated: 2021/01/03 18:30:50
7256 dnl -------------
7257 AC_DEFUN([CF_RPATH_HACK],
7258 [AC_REQUIRE([AC_PROG_FGREP])dnl
7259 AC_REQUIRE([CF_LD_RPATH_OPT])dnl
7260
7261 AC_MSG_CHECKING(for updated LDFLAGS)
7262 if test -n "$LD_RPATH_OPT" ; then
7263         AC_MSG_RESULT(maybe)
7264
7265         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
7266         cf_rpath_list="/usr/lib /lib"
7267         if test "$cf_ldd_prog" != no
7268         then
7269                 cf_rpath_oops=
7270
7271 AC_TRY_LINK([#include <stdio.h>],
7272                 [printf("Hello");],
7273                 [cf_rpath_oops=`"$cf_ldd_prog" "conftest$ac_exeext" | ${FGREP-fgrep} ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
7274                  cf_rpath_list=`"$cf_ldd_prog" "conftest$ac_exeext" | ${FGREP-fgrep} / | sed -e 's%^.*[[        ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
7275
7276                 # If we passed the link-test, but get a "not found" on a given library,
7277                 # this could be due to inept reconfiguration of gcc to make it only
7278                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
7279                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
7280                 # /usr/local libraries.
7281                 if test -n "$cf_rpath_oops"
7282                 then
7283                         for cf_rpath_src in $cf_rpath_oops
7284                         do
7285                                 for cf_rpath_dir in \
7286                                         /usr/local \
7287                                         /usr/pkg \
7288                                         /opt/sfw
7289                                 do
7290                                         if test -f "$cf_rpath_dir/lib/$cf_rpath_src"
7291                                         then
7292                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
7293                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
7294                                                 break
7295                                         fi
7296                                 done
7297                         done
7298                 fi
7299         fi
7300
7301         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
7302
7303         CF_RPATH_HACK_2(LDFLAGS)
7304         CF_RPATH_HACK_2(LIBS)
7305
7306         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
7307 else
7308         AC_MSG_RESULT(no)
7309 fi
7310 AC_SUBST(EXTRA_LDFLAGS)
7311 ])dnl
7312 dnl ---------------------------------------------------------------------------
7313 dnl CF_RPATH_HACK_2 version: 8 updated: 2021/01/01 13:31:04
7314 dnl ---------------
7315 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
7316 dnl EXTRA_LDFLAGS for each -L option found.
7317 dnl
7318 dnl $cf_rpath_list contains a list of directories to ignore.
7319 dnl
7320 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
7321 dnl      but LIBS often has misplaced -L options.
7322 AC_DEFUN([CF_RPATH_HACK_2],
7323 [
7324 CF_VERBOSE(...checking $1 [$]$1)
7325
7326 cf_rpath_dst=
7327 for cf_rpath_src in [$]$1
7328 do
7329         case "$cf_rpath_src" in
7330         (-L*)
7331
7332                 # check if this refers to a directory which we will ignore
7333                 cf_rpath_skip=no
7334                 if test -n "$cf_rpath_list"
7335                 then
7336                         for cf_rpath_item in $cf_rpath_list
7337                         do
7338                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
7339                                 then
7340                                         cf_rpath_skip=yes
7341                                         break
7342                                 fi
7343                         done
7344                 fi
7345
7346                 if test "$cf_rpath_skip" = no
7347                 then
7348                         # transform the option
7349                         if test "$LD_RPATH_OPT" = "-R " ; then
7350                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
7351                         else
7352                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
7353                         fi
7354
7355                         # if we have not already added this, add it now
7356                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
7357                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
7358                         then
7359                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
7360                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
7361                         fi
7362                 fi
7363                 ;;
7364         esac
7365         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
7366 done
7367 $1=$cf_rpath_dst
7368
7369 CF_VERBOSE(...checked $1 [$]$1)
7370 AC_SUBST(EXTRA_LDFLAGS)
7371 ])dnl
7372 dnl ---------------------------------------------------------------------------
7373 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
7374 dnl ------------------
7375 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
7376 dnl and libraries which do not update those variables.
7377 dnl
7378 dnl $1 = name of current macro
7379 define([CF_SAVE_XTRA_FLAGS],
7380 [
7381 cf_save_LIBS_$1="$LIBS"
7382 cf_save_CFLAGS_$1="$CFLAGS"
7383 cf_save_CPPFLAGS_$1="$CPPFLAGS"
7384 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
7385 for cf_X_CFLAGS in $X_CFLAGS
7386 do
7387         case "x$cf_X_CFLAGS" in
7388         x-[[IUD]]*)
7389                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
7390                 ;;
7391         *)
7392                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
7393                 ;;
7394         esac
7395 done
7396 ])dnl
7397 dnl ---------------------------------------------------------------------------
7398 dnl CF_SHARED_OPTS version: 109 updated: 2023/12/03 09:21:34
7399 dnl --------------
7400 dnl --------------
7401 dnl Attempt to determine the appropriate CC/LD options for creating a shared
7402 dnl library.
7403 dnl
7404 dnl Notes:
7405 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
7406 dnl the build-tree, i.e., by making use of the libraries that are compiled in
7407 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
7408 dnl shared library since that can lead to unexpected results at runtime.
7409 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
7410 dnl libraries are compiled in ../../lib
7411 dnl
7412 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
7413 dnl to install symbolic links to the rel/abi versions of shared libraries.
7414 dnl
7415 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
7416 dnl version when making symbolic links.
7417 dnl
7418 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
7419 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
7420 dnl (ex: libncurses.so.<ver>).
7421 dnl
7422 dnl Some loaders leave 'so_locations' lying around.  It is nice to clean up.
7423 AC_DEFUN([CF_SHARED_OPTS],
7424 [
7425         AC_REQUIRE([CF_LD_RPATH_OPT])
7426
7427         RM_SHARED_OPTS=
7428         LOCAL_LDFLAGS=
7429         LOCAL_LDFLAGS2=
7430         LD_SHARED_OPTS=
7431         INSTALL_LIB="-m 644"
7432         : ${rel_builddir:=.}
7433
7434         shlibdir=$libdir
7435         AC_SUBST(shlibdir)
7436
7437         MAKE_DLLS="#"
7438         AC_SUBST(MAKE_DLLS)
7439
7440         cf_cv_do_symlinks=no
7441         cf_ld_rpath_opt=
7442         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
7443
7444         AC_MSG_CHECKING(whether to use release or ABI version in shared library file names)
7445         AC_ARG_WITH(shlib-version,
7446         [[  --with-shlib-version[={rel|abi}] use release or ABI version in shared library file names]],
7447         [test -z "$withval" && withval=auto
7448         case "$withval" in
7449         (yes)
7450                 cf_cv_shlib_version=auto
7451                 ;;
7452         (rel|abi|auto)
7453                 cf_cv_shlib_version=$withval
7454                 ;;
7455         (*)
7456                 AC_MSG_RESULT($withval)
7457                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
7458                 ;;
7459         esac
7460         ],[cf_cv_shlib_version=auto])
7461         AC_MSG_RESULT($cf_cv_shlib_version)
7462
7463         cf_cv_rm_so_locs=no
7464         cf_try_cflags=
7465
7466         # Some less-capable ports of gcc support only -fpic
7467         CC_SHARED_OPTS=
7468
7469         cf_try_fPIC=no
7470         if test "$GCC" = yes
7471         then
7472                 cf_try_fPIC=yes
7473         else
7474                 case "$cf_cv_system_name" in
7475                 (*linux*)       # e.g., PGI compiler
7476                         cf_try_fPIC=yes
7477                         ;;
7478                 esac
7479         fi
7480
7481         if test "$cf_try_fPIC" = yes
7482         then
7483                 AC_MSG_CHECKING(which $CC option to use)
7484                 cf_save_CFLAGS="$CFLAGS"
7485                 for CC_SHARED_OPTS in -fPIC -fpic ''
7486                 do
7487                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
7488                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1; (void)x],[break],[])
7489                 done
7490                 AC_MSG_RESULT($CC_SHARED_OPTS)
7491                 CFLAGS="$cf_save_CFLAGS"
7492         fi
7493
7494         cf_cv_shlib_version_infix=no
7495
7496         case "$cf_cv_system_name" in
7497         (aix4.[3-9]*|aix[[5-7]]*)
7498                 if test "$GCC" = yes; then
7499                         CC_SHARED_OPTS='-Wl,-brtl'
7500                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
7501                 else
7502                         CC_SHARED_OPTS='-brtl'
7503                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
7504                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
7505                 fi
7506                 ;;
7507         (beos*)
7508                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
7509                 ;;
7510         (cygwin*)
7511                 CC_SHARED_OPTS=
7512                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
7513                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
7514                 cf_cv_shlib_version=cygdll
7515                 cf_cv_shlib_version_infix=cygdll
7516                 shlibdir=$bindir
7517                 MAKE_DLLS=
7518                 cat >mk_shared_lib.sh <<-CF_EOF
7519                 #!$SHELL
7520                 SHARED_LIB=\[$]1
7521                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
7522                 shift
7523                 cat <<-EOF
7524                 Linking shared library
7525                 ** SHARED_LIB \[$]SHARED_LIB
7526                 ** IMPORT_LIB \[$]IMPORT_LIB
7527 EOF
7528                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7529 CF_EOF
7530                 chmod +x mk_shared_lib.sh
7531                 ;;
7532         (msys*)
7533                 CC_SHARED_OPTS=
7534                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
7535                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
7536                 cf_cv_shlib_version=msysdll
7537                 cf_cv_shlib_version_infix=msysdll
7538                 shlibdir=$bindir
7539                 MAKE_DLLS=
7540                 cat >mk_shared_lib.sh <<-CF_EOF
7541                 #!$SHELL
7542                 SHARED_LIB=\[$]1
7543                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
7544                 shift
7545                 cat <<-EOF
7546                 Linking shared library
7547                 ** SHARED_LIB \[$]SHARED_LIB
7548                 ** IMPORT_LIB \[$]IMPORT_LIB
7549 EOF
7550                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7551 CF_EOF
7552                 chmod +x mk_shared_lib.sh
7553                 ;;
7554         (darwin*)
7555                 cf_try_cflags="no-cpp-precomp"
7556                 CC_SHARED_OPTS="-dynamic"
7557                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
7558                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
7559                 cf_cv_shlib_version_infix=yes
7560                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
7561                         cf_save_LDFLAGS=$LDFLAGS
7562                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
7563                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
7564                                 LDFLAGS=$cf_save_LDFLAGS])
7565                 if test "$cf_cv_ldflags_search_paths_first" = yes; then
7566                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
7567                 fi
7568                 ;;
7569         (haiku*)
7570                 CF_SHARED_SONAME
7571                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7572                 ;;
7573         (hpux[[7-8]]*)
7574                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
7575                 if test "$GCC" != yes; then
7576                         CC_SHARED_OPTS='+Z'
7577                 fi
7578                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
7579                 INSTALL_LIB="-m 555"
7580                 ;;
7581         (hpux*)
7582                 # (tested with gcc 2.7.2 -- I don't have c89)
7583                 if test "$GCC" = yes; then
7584                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
7585                 else
7586                         CC_SHARED_OPTS='+Z'
7587                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
7588                 fi
7589                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
7590                 # HP-UX shared libraries must be executable, and should be
7591                 # readonly to exploit a quirk in the memory manager.
7592                 INSTALL_LIB="-m 555"
7593                 ;;
7594         (interix*)
7595                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7596                 if test "$cf_cv_shlib_version" = rel; then
7597                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
7598                 else
7599                         cf_shared_soname='`basename $[@]`'
7600                 fi
7601                 CC_SHARED_OPTS=
7602                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
7603                 ;;
7604         (irix*)
7605                 if test "$cf_cv_enable_rpath" = yes ; then
7606                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7607                 fi
7608                 # tested with IRIX 5.2 and 'cc'.
7609                 if test "$GCC" != yes; then
7610                         CC_SHARED_OPTS='-KPIC'
7611                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
7612                 else
7613                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
7614                 fi
7615                 cf_cv_rm_so_locs=yes
7616                 ;;
7617         (linux*|gnu*|k*bsd*-gnu)
7618                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7619                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7620                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7621                 fi
7622                 if test "$cf_cv_enable_rpath" = yes ; then
7623                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7624                 fi
7625                 CF_SHARED_SONAME
7626                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7627                 ;;
7628         (mingw*msvc*)
7629                 cf_cv_shlib_version=msvcdll
7630                 cf_cv_shlib_version_infix=msvcdll
7631                 shlibdir=$bindir
7632                 MAKE_DLLS=
7633                 if test "$DFT_LWR_MODEL" = "shared" ; then
7634                         LOCAL_LDFLAGS="-link -dll"
7635                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7636                         EXTRA_LDFLAGS="-link -dll $EXTRA_LDFLAGS"
7637                 fi
7638                 CC_SHARED_OPTS=
7639                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ ${LD} [$]{CFLAGS}'
7640                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.lib"
7641                 cat >mk_shared_lib.sh <<-CF_EOF
7642                 #!$SHELL
7643                 SHARED_LIB=\[$]1
7644                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.lib/'\`
7645                 shift
7646                 my_ld=\[$]1
7647                 shift
7648                 cat <<-EOF
7649                 Linking shared library
7650                 ** SHARED LIB \$SHARED_LIB
7651                 ** IMPORT_LIB \$IMPORT_LIB
7652 EOF
7653                 args=\$(echo \[$]* | sed -E "s#-l(\w*)#\1.dll.lib#g" | sed -E "s#-L(\w*)#-LIBPATH:\1#g")
7654                 exec \$my_ld -DLL -IMPLIB:"\${IMPORT_LIB}" -OUT:"\${SHARED_LIB}" ${LDFLAGS} \$args
7655                 mv "\${IMPORT_LIB}" "\${IMPORT_LIB}"
7656 CF_EOF
7657                 chmod +x mk_shared_lib.sh
7658                 cat >mk_prog.sh <<-CF_EOF
7659                 #!$SHELL
7660                 shift
7661                 # Ignore first argument (compiler) and use LD (link.exe) unconditionally
7662                 LD="[$]LD"
7663                 clopts=()
7664                 ldopts=("/subsystem:console")
7665                 libs=()
7666                 isdll=0
7667                 while test \[$]# -gt 0; do
7668                         case "\[$]1" in
7669                                 -link)
7670                                         # ignore -link argument
7671                                         ;;
7672                                 -M[[TD]] | -M[[TD]]d)
7673                                         # ignore runtime-library option
7674                                         ;;
7675                                 -dll)
7676                                         isdll=1
7677                                         ;;
7678                                 -W* | -w*)
7679                                         # ignore warnings
7680                                         ;;
7681                                 -D*)
7682                                         clopts+=("\[$]1")
7683                                         ;;
7684                                 -I*)
7685                                         clopts+=("\[$]1")
7686                                         ;;
7687                                 -l*)
7688                                         libs+=("\`echo \"\[$]1\" | sed \"s/^-l//\"\`")
7689                                         ;;
7690                                 -L*)
7691                                         ldopts+=("\`echo \"\[$]1\" | sed \"s/^-L/-LIBPATH:/\"\`")
7692                                         ;;
7693                                 *.obj | *.o)
7694                                         ldopts+=("\[$]1")
7695                                         ;;
7696                                 -Wl,*)
7697                                         for linkarg in \`echo '\[$]1' | sed -e 's/-Wl,//' -e 's/,/ /'\`; do
7698                                                 ldopts+=("\[$]{linkarg}")
7699                                         done
7700                                         ;;
7701                                 *.lib)
7702                                         ldopts+=("\[$]1")
7703                                         ;;
7704                                 -o)
7705                                         shift
7706                                         ldopts+=("-out:\[$]1")
7707                                         ;;
7708                                 *)
7709                                         clopts+=("\[$]1")
7710                                         ldopts+=("\[$]1")
7711                                         ;;
7712                         esac
7713                         shift
7714                 done
7715                 if [[ "\$isdll" -ne 0 ]]; then
7716                         for lib in \[$]{libs[[*]]}; do
7717                                 ldopts+=("\[$]lib.dll.lib")
7718                         done
7719                 else
7720                         for lib in \[$]{libs[[*]]}; do
7721                                 ldopts+=("\[$]lib.lib")
7722                         done
7723                 fi
7724                 cat <<-EOF
7725                 Creating program
7726                 ** ld options:   "\[$]{ldopts[[@]]}"
7727 EOF
7728                 exec \[$]LD \[$]{ldopts[[@]]}
7729 CF_EOF
7730                 chmod +x mk_prog.sh
7731                 LINK_PROGS="$SHELL ${rel_builddir}/mk_prog.sh"
7732                 LINK_TESTS="$SHELL ${rel_builddir}/mk_prog.sh"
7733                 ;;
7734         (mingw*)
7735                 cf_cv_shlib_version=mingw
7736                 cf_cv_shlib_version_infix=mingw
7737                 shlibdir=$bindir
7738                 MAKE_DLLS=
7739                 if test "$DFT_LWR_MODEL" = "shared" ; then
7740                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
7741                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7742                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
7743                 fi
7744                 CC_SHARED_OPTS=
7745                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
7746                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
7747                 cat >mk_shared_lib.sh <<-CF_EOF
7748                 #!$SHELL
7749                 SHARED_LIB=\[$]1
7750                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
7751                 shift
7752                 cat <<-EOF
7753                 Linking shared library
7754                 ** SHARED_LIB \[$]SHARED_LIB
7755                 ** IMPORT_LIB \[$]IMPORT_LIB
7756 EOF
7757                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7758 CF_EOF
7759                 chmod +x mk_shared_lib.sh
7760                 ;;
7761         (openbsd[[2-9]].*|mirbsd*)
7762                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7763                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7764                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7765                 fi
7766                 if test "$cf_cv_enable_rpath" = yes ; then
7767                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7768                 fi
7769                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7770                 CF_SHARED_SONAME
7771                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7772                 ;;
7773         (nskJ*)
7774                 CC_SHARED_OPTS=
7775                 MK_SHARED_LIB='${LD} -Wshared -Weld=-export_all -o $[@]'
7776                 ;;
7777         (nskL*)
7778                 CC_SHARED_OPTS=
7779                 MK_SHARED_LIB='${LD} -Wshared -Wxld=-export_all -o $[@]'
7780                 ;;
7781         (nto-qnx*|openbsd*|freebsd[[12]].*)
7782                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7783                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
7784                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7785                 ;;
7786         (dragonfly*|freebsd*)
7787                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7788                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
7789                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
7790                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
7791                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7792                 fi
7793                 CF_SHARED_SONAME
7794                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7795                 ;;
7796         (netbsd*)
7797                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7798                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
7799                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
7800                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7801                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7802                         if test "$cf_cv_shlib_version" = auto; then
7803                         if test -f /usr/libexec/ld.elf_so; then
7804                                 cf_cv_shlib_version=abi
7805                         else
7806                                 cf_cv_shlib_version=rel
7807                         fi
7808                         fi
7809                         CF_SHARED_SONAME
7810                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
7811                 else
7812                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -o $[@]'
7813                 fi
7814                 ;;
7815         (osf*|mls+*)
7816                 # tested with OSF/1 V3.2 and 'cc'
7817                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
7818                 # link with shared libs).
7819                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
7820                 case "$host_os" in
7821                 (osf4*)
7822                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
7823                         ;;
7824                 esac
7825                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
7826                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7827                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7828                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7829                 fi
7830                 cf_cv_rm_so_locs=yes
7831                 ;;
7832         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
7833                 # tested with osr5.0.5
7834                 if test "$GCC" != yes; then
7835                         CC_SHARED_OPTS='-belf -KPIC'
7836                 fi
7837                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
7838                 if test "$cf_cv_enable_rpath" = yes ; then
7839                         # only way is to set LD_RUN_PATH but no switch for it
7840                         RUN_PATH=$libdir
7841                 fi
7842                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7843                 LINK_PROGS='LD_RUN_PATH=${libdir}'
7844                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
7845                 ;;
7846         (sunos4*)
7847                 # tested with SunOS 4.1.1 and gcc 2.7.0
7848                 if test "$GCC" != yes; then
7849                         CC_SHARED_OPTS='-KPIC'
7850                 fi
7851                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
7852                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7853                 ;;
7854         (solaris2*)
7855                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
7856                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
7857                 if test "$DFT_LWR_MODEL" = "shared" ; then
7858                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
7859                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7860                 fi
7861                 if test "$cf_cv_enable_rpath" = yes ; then
7862                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
7863                 fi
7864                 CF_SHARED_SONAME
7865                 if test "$GCC" != yes; then
7866                         cf_save_CFLAGS="$CFLAGS"
7867                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
7868                         do
7869                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
7870                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\\n");],[break])
7871                         done
7872                         CFLAGS="$cf_save_CFLAGS"
7873                         CC_SHARED_OPTS=$cf_shared_opts
7874                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
7875                 else
7876                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
7877                 fi
7878                 ;;
7879         (sysv5uw7*|unix_sv*)
7880                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
7881                 if test "$GCC" != yes; then
7882                         CC_SHARED_OPTS='-KPIC'
7883                 fi
7884                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
7885                 ;;
7886         (*)
7887                 CC_SHARED_OPTS='unknown'
7888                 MK_SHARED_LIB='echo unknown'
7889                 ;;
7890         esac
7891
7892         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
7893         case "$cf_cv_shlib_version" in
7894         (rel|abi)
7895                 case "$MK_SHARED_LIB" in
7896                 (*'-o $[@]')
7897                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
7898                         ;;
7899                 (*)
7900                         AC_MSG_WARN(ignored --with-shlib-version)
7901                         ;;
7902                 esac
7903                 ;;
7904         esac
7905
7906         if test -n "$cf_try_cflags"
7907         then
7908 cat > conftest.$ac_ext <<EOF
7909 #line __oline__ "${as_me:-configure}"
7910 #include <stdio.h>
7911 int main(int argc, char *argv[[]])
7912 {
7913         printf("hello\\n");
7914         return (argv[[argc-1]] == 0) ;
7915 }
7916 EOF
7917                 cf_save_CFLAGS="$CFLAGS"
7918                 for cf_opt in $cf_try_cflags
7919                 do
7920                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
7921                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
7922                         if AC_TRY_EVAL(ac_compile); then
7923                                 AC_MSG_RESULT(yes)
7924                                 cf_save_CFLAGS="$CFLAGS"
7925                         else
7926                                 AC_MSG_RESULT(no)
7927                         fi
7928                 done
7929                 CFLAGS="$cf_save_CFLAGS"
7930         fi
7931
7932
7933         # RPATH_LIST is a colon-separated list of directories
7934         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
7935         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
7936
7937         test "$cf_cv_rm_so_locs" = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
7938
7939         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
7940         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7941
7942         AC_SUBST(CC_SHARED_OPTS)
7943         AC_SUBST(LD_RPATH_OPT)
7944         AC_SUBST(LD_SHARED_OPTS)
7945         AC_SUBST(MK_SHARED_LIB)
7946         AC_SUBST(RM_SHARED_OPTS)
7947
7948         AC_SUBST(LINK_PROGS)
7949         AC_SUBST(LINK_TESTS)
7950
7951         AC_SUBST(EXTRA_LDFLAGS)
7952         AC_SUBST(LOCAL_LDFLAGS)
7953         AC_SUBST(LOCAL_LDFLAGS2)
7954
7955         AC_SUBST(INSTALL_LIB)
7956         AC_SUBST(RPATH_LIST)
7957 ])dnl
7958 dnl ---------------------------------------------------------------------------
7959 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
7960 dnl ----------------
7961 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
7962 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
7963 dnl option.
7964 dnl
7965 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
7966 dnl If missing, use "rel".
7967 define([CF_SHARED_SONAME],
7968 [
7969         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
7970         if test "$cf_cv_shlib_version" = rel; then
7971                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
7972         else
7973                 cf_cv_shared_soname='`basename $[@]`'
7974         fi
7975 ])
7976 dnl ---------------------------------------------------------------------------
7977 dnl CF_SIGWINCH version: 7 updated: 2023/02/18 17:41:25
7978 dnl -----------
7979 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
7980 dnl programs need this test).
7981 dnl
7982 dnl This is really a Mac OS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
7983 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
7984 dnl winsize declaration is left alone - we may revisit this if Apple choose to
7985 dnl break that part of the interface as well.
7986 AC_DEFUN([CF_SIGWINCH],
7987 [
7988 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
7989         AC_TRY_COMPILE([
7990 #include <sys/types.h>
7991 #include <sys/signal.h>
7992 ],[int x = SIGWINCH; (void)x],
7993         [cf_cv_define_sigwinch=yes],
7994         [AC_TRY_COMPILE([
7995 #undef _XOPEN_SOURCE
7996 #undef _POSIX_SOURCE
7997 #undef _POSIX_C_SOURCE
7998 #include <sys/types.h>
7999 #include <sys/signal.h>
8000 ],[int x = SIGWINCH; (void)x],
8001         [cf_cv_define_sigwinch=maybe],
8002         [cf_cv_define_sigwinch=no])
8003 ])
8004 ])
8005
8006 if test "$cf_cv_define_sigwinch" = maybe ; then
8007 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
8008 cf_cv_fixup_sigwinch=unknown
8009 cf_sigwinch=32
8010 while test "$cf_sigwinch" != 1
8011 do
8012         AC_TRY_COMPILE([
8013 #undef _XOPEN_SOURCE
8014 #undef _POSIX_SOURCE
8015 #undef _POSIX_C_SOURCE
8016 #include <sys/types.h>
8017 #include <sys/signal.h>
8018 ],[
8019 #if SIGWINCH != $cf_sigwinch
8020 #error SIGWINCH is not $cf_sigwinch
8021 #endif
8022 int x = SIGWINCH; (void)x],
8023         [cf_cv_fixup_sigwinch=$cf_sigwinch
8024          break])
8025
8026 cf_sigwinch="`expr "$cf_sigwinch" - 1`"
8027 done
8028 ])
8029
8030         if test "$cf_cv_fixup_sigwinch" != unknown ; then
8031                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
8032         fi
8033 fi
8034 ])dnl
8035 dnl ---------------------------------------------------------------------------
8036 dnl CF_SIG_ATOMIC_T version: 5 updated: 2020/03/10 18:53:47
8037 dnl ---------------
8038 dnl signal handler, but there are some gcc dependencies in that recommendation.
8039 dnl Try anyway.
8040 AC_DEFUN([CF_SIG_ATOMIC_T],
8041 [
8042 AC_MSG_CHECKING(for signal global datatype)
8043 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
8044         for cf_type in \
8045                 "volatile sig_atomic_t" \
8046                 "sig_atomic_t" \
8047                 "int"
8048         do
8049         AC_TRY_COMPILE([
8050 #include <sys/types.h>
8051 #include <signal.h>
8052 #include <stdio.h>
8053
8054 extern $cf_type x;
8055 $cf_type x;
8056 static void handler(int sig)
8057 {
8058         (void)sig;
8059         x = 5;
8060 }],
8061                 [signal(SIGINT, handler);
8062                  x = 1],
8063                 [cf_cv_sig_atomic_t=$cf_type],
8064                 [cf_cv_sig_atomic_t=no])
8065                 test "$cf_cv_sig_atomic_t" != no && break
8066         done
8067         ])
8068 AC_MSG_RESULT($cf_cv_sig_atomic_t)
8069 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
8070 ])dnl
8071 dnl ---------------------------------------------------------------------------
8072 dnl CF_SIZECHANGE version: 18 updated: 2021/09/04 06:35:04
8073 dnl -------------
8074 dnl Check for definitions & structures needed for window size-changing
8075 dnl
8076 dnl https://stackoverflow.com/questions/18878141/difference-between-structures-ttysize-and-winsize/50769952#50769952
8077 AC_DEFUN([CF_SIZECHANGE],
8078 [
8079 AC_REQUIRE([CF_STRUCT_TERMIOS])
8080 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
8081         cf_cv_sizechange=unknown
8082         cf_save_CPPFLAGS="$CPPFLAGS"
8083
8084 for cf_opts in "" "NEED_PTEM_H"
8085 do
8086
8087         CPPFLAGS="$cf_save_CPPFLAGS"
8088         if test -n "$cf_opts"
8089         then
8090                 CF_APPEND_TEXT(CPPFLAGS,-D$cf_opts)
8091         fi
8092         AC_TRY_COMPILE([#include <sys/types.h>
8093 #ifdef HAVE_TERMIOS_H
8094 #include <termios.h>
8095 #else
8096 #ifdef HAVE_TERMIO_H
8097 #include <termio.h>
8098 #endif
8099 #endif
8100
8101 #ifdef NEED_PTEM_H
8102 /* This is a workaround for SCO:  they neglected to define struct winsize in
8103  * termios.h -- it is only in termio.h and ptem.h
8104  */
8105 #include <sys/stream.h>
8106 #include <sys/ptem.h>
8107 #endif
8108
8109 #ifdef HAVE_SYS_IOCTL_H
8110 #include <sys/ioctl.h>
8111 #endif
8112 ],[
8113 #ifdef TIOCGSIZE
8114         struct ttysize win;     /* SunOS 3.0... */
8115         int y = win.ts_lines = 2;
8116         int x = win.ts_cols = 1;
8117         (void)y;
8118         (void)x;
8119 #else
8120 #ifdef TIOCGWINSZ
8121         struct winsize win;     /* everything else */
8122         int y = win.ws_row = 2;
8123         int x = win.ws_col = 1;
8124         (void)y;
8125         (void)x;
8126 #else
8127         no TIOCGSIZE or TIOCGWINSZ
8128 #endif /* TIOCGWINSZ */
8129 #endif /* TIOCGSIZE */
8130         ],
8131         [cf_cv_sizechange=yes],
8132         [cf_cv_sizechange=no])
8133
8134         CPPFLAGS="$cf_save_CPPFLAGS"
8135         if test "$cf_cv_sizechange" = yes ; then
8136                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
8137                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
8138                 break
8139         fi
8140 done
8141 ])
8142 if test "$cf_cv_sizechange" != no ; then
8143         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechange declarations are provided])
8144         case "$cf_cv_sizechange" in
8145         (NEED*)
8146                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
8147                 ;;
8148         esac
8149 fi
8150 ])dnl
8151 dnl ---------------------------------------------------------------------------
8152 dnl CF_SRC_MODULES version: 34 updated: 2023/04/22 11:51:06
8153 dnl --------------
8154 dnl For each parameter, test if the source-directory exists, and if it contains
8155 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
8156 dnl use in CF_LIB_RULES.
8157 dnl
8158 dnl This uses the configured value to make the lists SRC_SUBDIRS and
8159 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
8160 AC_DEFUN([CF_SRC_MODULES],
8161 [
8162 AC_REQUIRE([CF_CHECK_GNAT_VERSION])
8163 AC_MSG_CHECKING(for src modules)
8164
8165 # dependencies and linker-arguments for test-programs
8166 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
8167 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
8168 if test "$DFT_LWR_MODEL" = "libtool"; then
8169         TEST_ARGS="${TEST_DEPS}"
8170         TEST_ARG2="${TEST_DEP2}"
8171 else
8172         TEST_ARGS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
8173         TEST_ARG2="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARG2"
8174 fi
8175
8176 PC_MODULES_TO_MAKE="ncurses${USE_ARG_SUFFIX}"
8177 cf_cv_src_modules=
8178 for cf_dir in $1
8179 do
8180         if test -f "$srcdir/$cf_dir/modules" ; then
8181
8182                 if test -z "$cf_cv_src_modules"; then
8183                         cf_cv_src_modules=$cf_dir
8184                 else
8185                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
8186                 fi
8187
8188                 # Make the ncurses_cfg.h file record the library interface files as
8189                 # well.  These are header files that are the same name as their
8190                 # directory.  Ncurses is the only library that does not follow
8191                 # that pattern.
8192                 if test -f "$srcdir/${cf_dir}/${cf_dir}.h" ; then
8193                         CF_UPPER(cf_have_include,$cf_dir)
8194                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
8195                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
8196                         CF_MAP_LIB_BASENAME(TEST_ROOT,$cf_dir)
8197                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEPS"
8198                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEP2"
8199                         if test "$DFT_LWR_MODEL" = "libtool"; then
8200                                 TEST_ARGS="${TEST_DEPS}"
8201                                 TEST_ARG2="${TEST_DEP2}"
8202                         else
8203                                 TEST_ARGS="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARGS"
8204                                 TEST_ARG2="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARG2"
8205                         fi
8206                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${USE_ARG_SUFFIX}"
8207                 fi
8208         fi
8209 done
8210 AC_MSG_RESULT($cf_cv_src_modules)
8211
8212 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
8213 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
8214
8215 AC_SUBST(TEST_ARGS)
8216 AC_SUBST(TEST_DEPS)
8217
8218 AC_SUBST(TEST_ARG2)
8219 AC_SUBST(TEST_DEP2)
8220
8221 SRC_SUBDIRS=
8222 if test "x$cf_with_manpages" != xno ; then
8223         SRC_SUBDIRS="$SRC_SUBDIRS man"
8224 fi
8225 SRC_SUBDIRS="$SRC_SUBDIRS include"
8226 for cf_dir in $cf_cv_src_modules
8227 do
8228         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
8229 done
8230 if test "x$cf_with_tests" != "xno" ; then
8231         SRC_SUBDIRS="$SRC_SUBDIRS test"
8232 fi
8233 # always make this, to install the ncurses-config script
8234 SRC_SUBDIRS="$SRC_SUBDIRS misc"
8235 if test "$cf_with_cxx_binding" != no; then
8236         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${USE_ARG_SUFFIX}"
8237         SRC_SUBDIRS="$SRC_SUBDIRS c++"
8238 fi
8239
8240 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
8241 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
8242
8243 AC_SUBST(PC_MODULES_TO_MAKE)
8244
8245 ADA_SUBDIRS=
8246 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f "$srcdir/Ada95/Makefile.in" ; then
8247         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
8248         ADA_SUBDIRS="gen src"
8249         if test "x$cf_with_tests" != "xno" ; then
8250                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
8251         fi
8252 fi
8253
8254 SUB_MAKEFILES=
8255 for cf_dir in $SRC_SUBDIRS
8256 do
8257         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
8258 done
8259
8260 if test -n "$ADA_SUBDIRS"; then
8261         for cf_dir in $ADA_SUBDIRS
8262         do
8263                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
8264         done
8265         AC_SUBST(ADA_SUBDIRS)
8266 fi
8267 ])dnl
8268 dnl ---------------------------------------------------------------------------
8269 dnl CF_STDCPP_LIBRARY version: 12 updated: 2021/01/01 13:31:04
8270 dnl -----------------
8271 dnl Check for -lstdc++, which is GNU's standard C++ library.
8272 dnl If $CXXLIBS is set, add that to the libraries used for test-linking.
8273 dnl If -lstdc++ was not already added to $LIBS or $CXXLIBS, and is needed,
8274 dnl add it to $CXXLIBS.
8275 AC_DEFUN([CF_STDCPP_LIBRARY],
8276 [
8277 if test -n "$GXX" ; then
8278
8279         cf_save="$LIBS"
8280         LIBS="$LIBS $CXXLIBS"
8281         AC_MSG_CHECKING(if we already have C++ library)
8282         AC_TRY_LINK([
8283                         #include <iostream>],[
8284                         std::cout << "Hello World!" << std::endl;],
8285                 [cf_have_libstdcpp=yes],
8286                 [cf_have_libstdcpp=no])
8287         AC_MSG_RESULT($cf_have_libstdcpp)
8288         LIBS="$cf_save"
8289
8290         if test "$cf_have_libstdcpp" != yes
8291         then
8292                 case "$cf_cv_system_name" in
8293                 (os2*)
8294                         if test -z "`g++ -dM -E - < /dev/null | grep __KLIBC__`"; then
8295                                 cf_stdcpp_libname=stdcpp
8296                         else
8297                                 cf_stdcpp_libname=stdc++
8298                         fi
8299                         ;;
8300                 (*)
8301                         cf_stdcpp_libname=stdc++
8302                         ;;
8303                 esac
8304
8305                 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
8306                         cf_save="$LIBS"
8307                         LIBS="$LIBS $CXXLIBS"
8308                         CF_ADD_LIB($cf_stdcpp_libname)
8309                 AC_TRY_LINK([
8310                                 #include <iostream>],[
8311                                 std::cout << "Hello World!" << std::endl;],
8312                         [cf_cv_libstdcpp=yes],
8313                         [cf_cv_libstdcpp=no])
8314                         LIBS="$cf_save"
8315                 ])
8316                 test "$cf_cv_libstdcpp" = yes && { CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS) }
8317         fi
8318 fi
8319 ])dnl
8320 dnl ---------------------------------------------------------------------------
8321 dnl CF_STRIP_G_OPT version: 4 updated: 2021/01/02 09:31:20
8322 dnl --------------
8323 dnl     Remove "-g" option from the compiler options
8324 AC_DEFUN([CF_STRIP_G_OPT],
8325 [$1=`echo "${$1}" | CF__SED_TRIMBLANKS(-e 's%-g %%' -e 's%-g$%%')`])dnl
8326 dnl ---------------------------------------------------------------------------
8327 dnl CF_STRUCT_SIGACTION version: 6 updated: 2023/12/03 09:21:34
8328 dnl -------------------
8329 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
8330 dnl do this if we've found the sigaction function.
8331 AC_DEFUN([CF_STRUCT_SIGACTION],[
8332 AC_REQUIRE([CF_XOPEN_SOURCE])
8333
8334 if test "$ac_cv_func_sigaction" = yes; then
8335 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
8336 AC_TRY_COMPILE([
8337 #include <sys/types.h>
8338 #include <signal.h>],
8339         [struct sigaction act; (void)act],
8340         [sigact_bad=no],
8341         [
8342 AC_TRY_COMPILE([
8343 #define _POSIX_SOURCE
8344 #include <sys/types.h>
8345 #include <signal.h>],
8346         [struct sigaction act; (void)act],
8347         [sigact_bad=yes
8348          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
8349          [sigact_bad=unknown])])
8350 AC_MSG_RESULT($sigact_bad)
8351 fi
8352 ])dnl
8353 dnl ---------------------------------------------------------------------------
8354 dnl CF_STRUCT_TERMIOS version: 13 updated: 2023/12/03 19:38:54
8355 dnl -----------------
8356 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
8357 AC_DEFUN([CF_STRUCT_TERMIOS],[
8358 AC_REQUIRE([CF_XOPEN_SOURCE])
8359
8360 AC_CHECK_HEADERS( \
8361 termio.h \
8362 termios.h \
8363 unistd.h \
8364 sys/ioctl.h \
8365 sys/termio.h \
8366 )
8367
8368 if test "$ac_cv_header_termios_h" = yes ; then
8369         case "$CFLAGS $CPPFLAGS" in
8370         (*-D_POSIX_SOURCE*)
8371                 termios_bad=dunno ;;
8372         (*)     termios_bad=maybe ;;
8373         esac
8374         if test "$termios_bad" = maybe ; then
8375         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
8376         AC_TRY_COMPILE([#include <termios.h>],
8377                 [struct termios foo; int x = (int)(foo.c_iflag = 1); (void)x],
8378                 termios_bad=no, [
8379                 AC_TRY_COMPILE([
8380 #define _POSIX_SOURCE
8381 #include <termios.h>],
8382                         [struct termios foo; int x = (int)(foo.c_iflag = 2); (void)x],
8383                         termios_bad=unknown,
8384                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
8385                         ])
8386         AC_MSG_RESULT($termios_bad)
8387         fi
8388 fi
8389 ])dnl
8390 dnl ---------------------------------------------------------------------------
8391 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
8392 dnl --------------
8393 dnl Construct a search-list for a nonstandard header/lib-file
8394 dnl     $1 = the variable to return as result
8395 dnl     $2 = the package name
8396 dnl     $3 = the subdirectory, e.g., bin, include or lib
8397 AC_DEFUN([CF_SUBDIR_PATH],
8398 [
8399 $1=
8400
8401 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
8402
8403 for cf_subdir_prefix in \
8404         /usr \
8405         /usr/local \
8406         /usr/pkg \
8407         /opt \
8408         /opt/local \
8409         [$]HOME
8410 do
8411         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
8412 done
8413 ])dnl
8414 dnl ---------------------------------------------------------------------------
8415 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
8416 dnl -----------
8417 dnl     Shorthand macro for substituting things that the user may override
8418 dnl     with an environment variable.
8419 dnl
8420 dnl     $1 = condition to pass to "test"
8421 dnl     $2 = environment variable
8422 dnl     $3 = value if the test succeeds
8423 dnl     $4 = value if the test fails
8424 AC_DEFUN([CF_SUBST_IF],
8425 [
8426 if test $1 ; then
8427         $2=$3
8428 ifelse($4,,,[else
8429         $2=$4])
8430 fi
8431 AC_SUBST($2)
8432 ])dnl
8433 dnl ---------------------------------------------------------------------------
8434 dnl CF_SUBST_NCURSES_VERSION version: 11 updated: 2023/01/07 16:32:06
8435 dnl ------------------------
8436 dnl Get the version-number for use in shared-library naming, etc.
8437 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
8438 [AC_REQUIRE([AC_PROG_EGREP])dnl
8439
8440 NCURSES_MAJOR="`${EGREP-egrep} '^NCURSES_MAJOR[[        ]]*=' "$srcdir/dist.mk" | sed -e 's/^[[^0-9]]*//'`"
8441 NCURSES_MINOR="`${EGREP-egrep} '^NCURSES_MINOR[[        ]]*=' "$srcdir/dist.mk" | sed -e 's/^[[^0-9]]*//'`"
8442 NCURSES_PATCH="`${EGREP-egrep} '^NCURSES_PATCH[[        ]]*=' "$srcdir/dist.mk" | sed -e 's/^[[^0-9]]*//'`"
8443 cf_cv_abi_version=${NCURSES_MAJOR}
8444 cf_cv_abi_default=${NCURSES_MAJOR}
8445 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
8446 dnl Show the computed version, for logging
8447 cf_cv_timestamp=`date`
8448 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_default ($cf_cv_timestamp))
8449 dnl We need these values in the generated headers
8450 AC_SUBST(NCURSES_MAJOR)
8451 AC_SUBST(NCURSES_MINOR)
8452 AC_SUBST(NCURSES_PATCH)
8453 dnl We need these values in the generated makefiles
8454 AC_SUBST(cf_cv_rel_version)
8455 AC_SUBST(cf_cv_abi_version)
8456 AC_SUBST(cf_cv_abi_default)
8457 AC_SUBST(cf_cv_builtin_bool)
8458 AC_SUBST(cf_cv_header_stdbool_h)
8459 AC_SUBST(cf_cv_type_of_bool)dnl
8460 ])dnl
8461 dnl ---------------------------------------------------------------------------
8462 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
8463 dnl ------------------
8464 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
8465 dnl older SCO configurations.
8466 AC_DEFUN([CF_SYS_TIME_SELECT],
8467 [
8468 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
8469 AC_CACHE_VAL(cf_cv_sys_time_select,[
8470 AC_TRY_COMPILE([
8471 #include <sys/types.h>
8472 #ifdef HAVE_SYS_TIME_H
8473 #include <sys/time.h>
8474 #endif
8475 #ifdef HAVE_SYS_SELECT_H
8476 #include <sys/select.h>
8477 #endif
8478 ],[],[cf_cv_sys_time_select=yes],
8479          [cf_cv_sys_time_select=no])
8480          ])
8481 AC_MSG_RESULT($cf_cv_sys_time_select)
8482 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
8483 ])dnl
8484 dnl ---------------------------------------------------------------------------
8485 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
8486 dnl ---------------
8487 dnl Define a top_builddir symbol, for applications that need an absolute path.
8488 AC_DEFUN([CF_TOP_BUILDDIR],
8489 [
8490 top_builddir=ifelse($1,,`pwd`,$1)
8491 AC_SUBST(top_builddir)
8492 ])dnl
8493 dnl ---------------------------------------------------------------------------
8494 dnl CF_TRY_PKG_CONFIG version: 6 updated: 2020/12/31 10:54:15
8495 dnl -----------------
8496 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
8497 dnl available in that form.
8498 dnl
8499 dnl $1 = package name, which may be a shell variable
8500 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
8501 dnl $3 = logic to use if pkg-config does not have the package
8502 AC_DEFUN([CF_TRY_PKG_CONFIG],[
8503 AC_REQUIRE([CF_PKG_CONFIG])
8504
8505 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists "$1"; then
8506         CF_VERBOSE(found package $1)
8507         cf_pkgconfig_incs="`$PKG_CONFIG --cflags "$1" 2>/dev/null`"
8508         cf_pkgconfig_libs="`$PKG_CONFIG --libs   "$1" 2>/dev/null`"
8509         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
8510         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
8511         CF_ADD_CFLAGS($cf_pkgconfig_incs)
8512         CF_ADD_LIBS($cf_pkgconfig_libs)
8513         ifelse([$2],,:,[$2])
8514 else
8515         cf_pkgconfig_incs=
8516         cf_pkgconfig_libs=
8517         ifelse([$3],,:,[$3])
8518 fi
8519 ])
8520 dnl ---------------------------------------------------------------------------
8521 dnl CF_TRY_XOPEN_SOURCE version: 4 updated: 2022/09/10 15:16:16
8522 dnl -------------------
8523 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
8524 dnl can define it successfully.
8525 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
8526 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
8527         AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,
8528         [cf_cv_xopen_source=no],
8529         [cf_save="$CPPFLAGS"
8530          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
8531          AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,
8532                 [cf_cv_xopen_source=no],
8533                 [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
8534                 CPPFLAGS="$cf_save"
8535         ])
8536 ])
8537
8538 if test "$cf_cv_xopen_source" != no ; then
8539         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
8540         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
8541         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
8542         CF_APPEND_CFLAGS($cf_temp_xopen_source)
8543 fi
8544 ])
8545 dnl ---------------------------------------------------------------------------
8546 dnl CF_TYPEOF_CHTYPE version: 11 updated: 2023/01/05 17:57:59
8547 dnl ----------------
8548 dnl Determine the type we should use for chtype (and attr_t, which is treated
8549 dnl as the same thing).  We want around 32 bits, so on most machines want a
8550 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
8551 dnl wide characters, we have to have a type compatible with that, as well.
8552 AC_DEFUN([CF_TYPEOF_CHTYPE],
8553 [
8554 AC_MSG_CHECKING([for type of chtype])
8555 AC_CACHE_VAL(cf_cv_typeof_chtype,[
8556                 AC_TRY_RUN([
8557 $ac_includes_default
8558 #define WANT_BITS 31
8559 int main(void)
8560 {
8561         FILE *fp = fopen("cf_test.out", "w");
8562         if (fp != 0) {
8563                 char *result = "long";
8564                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
8565                         int n;
8566                         unsigned int x, y;
8567                         for (n = 0; n < WANT_BITS; n++) {
8568                                 x = (1 << n);
8569                                 y = (x >> n);
8570                                 if (y != 1 || x == 0) {
8571                                         x = 0;
8572                                         break;
8573                                 }
8574                         }
8575                         /*
8576                          * If x is nonzero, an int is big enough for the bits
8577                          * that we want.
8578                          */
8579                         result = (x != 0) ? "int" : "long";
8580                 }
8581                 fputs(result, fp);
8582                 fclose(fp);
8583         }
8584         ${cf_cv_main_return:-return}(0);
8585 }
8586                 ],
8587                 [cf_cv_typeof_chtype=`cat cf_test.out`],
8588                 [cf_cv_typeof_chtype=long],
8589                 [cf_cv_typeof_chtype=long])
8590                 rm -f cf_test.out
8591         ])
8592 AC_MSG_RESULT($cf_cv_typeof_chtype)
8593
8594 AC_SUBST(cf_cv_typeof_chtype)
8595 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
8596 ])dnl
8597 dnl ---------------------------------------------------------------------------
8598 dnl CF_TYPE_SIGACTION version: 5 updated: 2023/12/03 09:21:34
8599 dnl -----------------
8600 dnl
8601 AC_DEFUN([CF_TYPE_SIGACTION],
8602 [
8603 AC_MSG_CHECKING([for type sigaction_t])
8604 AC_CACHE_VAL(cf_cv_type_sigaction,[
8605         AC_TRY_COMPILE([
8606 #include <signal.h>],
8607                 [sigaction_t x; (void)x],
8608                 [cf_cv_type_sigaction=yes],
8609                 [cf_cv_type_sigaction=no])])
8610 AC_MSG_RESULT($cf_cv_type_sigaction)
8611 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
8612 ])dnl
8613 dnl ---------------------------------------------------------------------------
8614 dnl CF_UNSIGNED_LITERALS version: 3 updated: 2023/12/03 10:02:17
8615 dnl --------------------
8616 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
8617 dnl won't, but they're still there.
8618 AC_DEFUN([CF_UNSIGNED_LITERALS],
8619 [
8620 AC_MSG_CHECKING([if unsigned literals are legal])
8621 AC_CACHE_VAL(cf_cv_unsigned_literals,[
8622         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1; (void)x],
8623                 [cf_cv_unsigned_literals=yes],
8624                 [cf_cv_unsigned_literals=no])
8625         ])
8626 AC_MSG_RESULT($cf_cv_unsigned_literals)
8627 ])dnl
8628 dnl ---------------------------------------------------------------------------
8629 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
8630 dnl --------
8631 dnl Make an uppercase version of a variable
8632 dnl $1=uppercase($2)
8633 AC_DEFUN([CF_UPPER],
8634 [
8635 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
8636 ])dnl
8637 dnl ---------------------------------------------------------------------------
8638 dnl CF_UTF8_LIB version: 10 updated: 2023/01/11 04:05:23
8639 dnl -----------
8640 dnl Check for multibyte support, and if not found, utf8 compatibility library
8641 AC_DEFUN([CF_UTF8_LIB],
8642 [
8643 AC_HAVE_HEADERS(wchar.h)
8644 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
8645         cf_save_LIBS="$LIBS"
8646         AC_TRY_LINK([
8647 $ac_includes_default
8648 #ifdef HAVE_WCHAR_H
8649 #include <wchar.h>
8650 #endif
8651 ],[putwc(0,0);],
8652         [cf_cv_utf8_lib=yes],
8653         [CF_FIND_LINKAGE([
8654 #include <libutf8.h>],[putwc(0,0);],utf8,
8655                 [cf_cv_utf8_lib=add-on],
8656                 [cf_cv_utf8_lib=no])
8657 ])])
8658
8659 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
8660 # ncurses/ncursesw:
8661 if test "$cf_cv_utf8_lib" = "add-on" ; then
8662         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
8663         CF_ADD_INCDIR($cf_cv_header_path_utf8)
8664         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
8665         CF_ADD_LIBS($cf_cv_library_file_utf8)
8666 fi
8667 ])dnl
8668 dnl ---------------------------------------------------------------------------
8669 dnl CF_VA_COPY version: 6 updated: 2018/12/04 18:14:25
8670 dnl ----------
8671 dnl check for va_copy, part of stdarg.h starting with ISO C 1999.
8672 dnl Also, workaround for glibc's __va_copy, by checking for both.
8673 dnl Finally, try to accommodate pre-ISO C 1999 headers.
8674 AC_DEFUN([CF_VA_COPY],[
8675 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
8676 AC_TRY_LINK([
8677 #include <stdarg.h>
8678 ],[
8679         static va_list dst;
8680         static va_list src;
8681         va_copy(dst, src)],
8682         cf_cv_have_va_copy=yes,
8683         cf_cv_have_va_copy=no)])
8684
8685 if test "$cf_cv_have_va_copy" = yes;
8686 then
8687         AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
8688 else # !cf_cv_have_va_copy
8689
8690 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
8691 AC_TRY_LINK([
8692 #include <stdarg.h>
8693 ],[
8694         static va_list dst;
8695         static va_list src;
8696         __va_copy(dst, src)],
8697         cf_cv_have___va_copy=yes,
8698         cf_cv_have___va_copy=no)])
8699
8700 if test "$cf_cv_have___va_copy" = yes
8701 then
8702         AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
8703 else # !cf_cv_have___va_copy
8704
8705 AC_CACHE_CHECK(for __builtin_va_copy, cf_cv_have___builtin_va_copy,[
8706 AC_TRY_LINK([
8707 #include <stdarg.h>
8708 ],[
8709         static va_list dst;
8710         static va_list src;
8711         __builtin_va_copy(dst, src)],
8712         cf_cv_have___builtin_va_copy=yes,
8713         cf_cv_have___builtin_va_copy=no)])
8714
8715 test "$cf_cv_have___builtin_va_copy" = yes &&
8716         AC_DEFINE(HAVE___BUILTIN_VA_COPY,1,[Define to 1 if we have __builtin_va_copy])
8717
8718 fi # cf_cv_have___va_copy
8719
8720 fi # cf_cv_have_va_copy
8721
8722 case "${cf_cv_have_va_copy}${cf_cv_have___va_copy}${cf_cv_have___builtin_va_copy}" in
8723 (*yes*)
8724         ;;
8725
8726 (*)
8727         AC_CACHE_CHECK(if we can simply copy va_list, cf_cv_pointer_va_list,[
8728 AC_TRY_LINK([
8729 #include <stdarg.h>
8730 ],[
8731         va_list dst;
8732         va_list src;
8733         dst = src],
8734         cf_cv_pointer_va_list=yes,
8735         cf_cv_pointer_va_list=no)])
8736
8737         if test "$cf_cv_pointer_va_list" = no
8738         then
8739                 AC_CACHE_CHECK(if we can copy va_list indirectly, cf_cv_array_va_list,[
8740 AC_TRY_LINK([
8741 #include <stdarg.h>
8742 ],[
8743         va_list dst;
8744         va_list src;
8745         *dst = *src],
8746                         cf_cv_array_va_list=yes,
8747                         cf_cv_array_va_list=no)])
8748                 test "$cf_cv_array_va_list" = yes && AC_DEFINE(ARRAY_VA_LIST,1,[Define to 1 if we can copy va_list indirectly])
8749         fi
8750         ;;
8751 esac
8752 ])
8753 dnl ---------------------------------------------------------------------------
8754 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
8755 dnl ----------
8756 dnl Use AC_VERBOSE w/o the warnings
8757 AC_DEFUN([CF_VERBOSE],
8758 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
8759 CF_MSG_LOG([$1])
8760 ])dnl
8761 dnl ---------------------------------------------------------------------------
8762 dnl CF_VERSION_INFO version: 8 updated: 2021/01/01 13:31:04
8763 dnl ---------------
8764 dnl Define several useful symbols derived from the VERSION file.  A separate
8765 dnl file is preferred to embedding the version numbers in various scripts.
8766 dnl (automake is a textbook-example of why the latter is a bad idea, but there
8767 dnl are others).
8768 dnl
8769 dnl The file contents are:
8770 dnl     libtool-version release-version patch-version
8771 dnl or
8772 dnl     release-version
8773 dnl where
8774 dnl     libtool-version (see ?) consists of 3 integers separated by '.'
8775 dnl     release-version consists of a major version and minor version
8776 dnl             separated by '.', optionally followed by a patch-version
8777 dnl             separated by '-'.  The minor version need not be an
8778 dnl             integer (but it is preferred).
8779 dnl     patch-version is an integer in the form yyyymmdd, so ifdef's and
8780 dnl             scripts can easily compare versions.
8781 dnl
8782 dnl If libtool is used, the first form is required, since CF_WITH_LIBTOOL
8783 dnl simply extracts the first field using 'cut -f1'.
8784 dnl
8785 dnl Optional parameters:
8786 dnl $1 = internal name for package
8787 dnl $2 = external name for package
8788 AC_DEFUN([CF_VERSION_INFO],
8789 [
8790 if test -f "$srcdir/VERSION" ; then
8791         AC_MSG_CHECKING(for package version)
8792
8793         # if there are not enough fields, cut returns the last one...
8794         cf_field1=`sed -e '2,$d' "$srcdir/VERSION" |cut -f1`
8795         cf_field2=`sed -e '2,$d' "$srcdir/VERSION" |cut -f2`
8796         cf_field3=`sed -e '2,$d' "$srcdir/VERSION" |cut -f3`
8797
8798         # this is how CF_BUNDLED_INTL uses $VERSION:
8799         VERSION="$cf_field1"
8800
8801         VERSION_MAJOR=`echo "$cf_field2" | sed -e 's/\..*//'`
8802         test -z "$VERSION_MAJOR" && AC_MSG_ERROR(missing major-version)
8803
8804         VERSION_MINOR=`echo "$cf_field2" | sed -e 's/^[[^.]]*\.//' -e 's/-.*//'`
8805         test -z "$VERSION_MINOR" && AC_MSG_ERROR(missing minor-version)
8806
8807         AC_MSG_RESULT(${VERSION_MAJOR}.${VERSION_MINOR})
8808
8809         AC_MSG_CHECKING(for package patch date)
8810         VERSION_PATCH=`echo "$cf_field3" | sed -e 's/^[[^-]]*-//'`
8811         case .$VERSION_PATCH in
8812         (.)
8813                 AC_MSG_ERROR(missing patch-date $VERSION_PATCH)
8814                 ;;
8815         (.[[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]])
8816                 ;;
8817         (*)
8818                 AC_MSG_ERROR(illegal patch-date $VERSION_PATCH)
8819                 ;;
8820         esac
8821         AC_MSG_RESULT($VERSION_PATCH)
8822 else
8823         AC_MSG_ERROR(did not find $srcdir/VERSION)
8824 fi
8825
8826 # show the actual data that we have for versions:
8827 CF_VERBOSE(ABI VERSION $VERSION)
8828 CF_VERBOSE(VERSION_MAJOR $VERSION_MAJOR)
8829 CF_VERBOSE(VERSION_MINOR $VERSION_MINOR)
8830 CF_VERBOSE(VERSION_PATCH $VERSION_PATCH)
8831
8832 AC_SUBST(VERSION)
8833 AC_SUBST(VERSION_MAJOR)
8834 AC_SUBST(VERSION_MINOR)
8835 AC_SUBST(VERSION_PATCH)
8836
8837 dnl if a package name is given, define its corresponding version info.  We
8838 dnl need the package name to ensure that the defined symbols are unique.
8839 ifelse($1,,,[
8840         cf_PACKAGE=$1
8841         PACKAGE=ifelse($2,,$1,$2)
8842         AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",[Define to the package-name])
8843         AC_SUBST(PACKAGE)
8844         CF_UPPER(cf_PACKAGE,$cf_PACKAGE)
8845         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_VERSION,"${VERSION_MAJOR}.${VERSION_MINOR}")
8846         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_PATCHDATE,${VERSION_PATCH})
8847 ])
8848 ])dnl
8849 dnl ---------------------------------------------------------------------------
8850 dnl CF_WCHAR_TYPE version: 5 updated: 2023/12/03 09:21:34
8851 dnl -------------
8852 dnl Check if type wide-character type $1 is declared, and if so, which header
8853 dnl file is needed.  The second parameter is used to set a shell variable when
8854 dnl the type is not found.  The first parameter sets a shell variable for the
8855 dnl opposite sense.
8856 AC_DEFUN([CF_WCHAR_TYPE],
8857 [
8858 # This is needed on Tru64 5.0 to declare $1
8859 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
8860 AC_TRY_COMPILE([
8861 #include <stdlib.h>
8862 #include <stdarg.h>
8863 #include <stdio.h>
8864 #ifdef HAVE_LIBUTF8_H
8865 #include <libutf8.h>
8866 #endif],
8867         [$1 state; (void)state],
8868         [cf_cv_$1=no],
8869         [AC_TRY_COMPILE([
8870 #include <stdlib.h>
8871 #include <stdarg.h>
8872 #include <stdio.h>
8873 #include <wchar.h>
8874 #ifdef HAVE_LIBUTF8_H
8875 #include <libutf8.h>
8876 #endif],
8877         [$1 value; (void) value],
8878         [cf_cv_$1=yes],
8879         [cf_cv_$1=unknown])])])
8880
8881 if test "$cf_cv_$1" = yes ; then
8882         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
8883         NEED_WCHAR_H=1
8884 fi
8885
8886 ifelse([$2],,,[
8887 # if we do not find $1 in either place, use substitution to provide a fallback.
8888 if test "$cf_cv_$1" = unknown ; then
8889         $2=1
8890 fi
8891 ])
8892 ifelse($3,,,[
8893 # if we find $1 in either place, use substitution to provide a fallback.
8894 if test "$cf_cv_$1" != unknown ; then
8895         $3=1
8896 fi
8897 ])
8898 ])dnl
8899 dnl ---------------------------------------------------------------------------
8900 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
8901 dnl ---------------
8902 dnl Check for compiler-support for weak symbols.
8903 dnl This works with "recent" gcc.
8904 AC_DEFUN([CF_WEAK_SYMBOLS],[
8905 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
8906
8907 AC_TRY_COMPILE([
8908 #include <stdio.h>],
8909 [
8910 #if defined(__GNUC__)
8911 #  if defined __USE_ISOC99
8912 #    define _cat_pragma(exp)    _Pragma(#exp)
8913 #    define _weak_pragma(exp)   _cat_pragma(weak name)
8914 #  else
8915 #    define _weak_pragma(exp)
8916 #  endif
8917 #  define _declare(name)        __extension__ extern __typeof__(name) name
8918 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
8919 #endif
8920
8921 weak_symbol(fopen);
8922 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
8923 ])
8924 ])dnl
8925 dnl ---------------------------------------------------------------------------
8926 dnl CF_WITH_ABI_ALTERED version: 1 updated: 2023/01/07 16:32:06
8927 dnl -------------------
8928 dnl Provide a way to override the displayed ABI version, e.g., in filenames.
8929 dnl Check this option after using the ABI version in configuration decisions.
8930 AC_DEFUN([CF_WITH_ABI_ALTERED],[
8931 AC_REQUIRE([CF_WITH_ABI_VERSION])
8932 AC_REQUIRE([CF_ABI_DEFAULTS])
8933 AC_ARG_WITH(abi-altered,
8934 [  --with-abi-altered=XXX  override visible ABI version, for packaging],[
8935         CF_NUMBER_SYNTAX($withval,ABI altered)
8936         if test "$cf_cv_abi_version" != "$withval"
8937         then
8938                 AC_MSG_WARN(altering visible ABI from $cf_cv_abi_version to $withval)
8939                 cf_cv_abi_version=$withval
8940         fi
8941 ])dnl
8942 ])dnl
8943 dnl ---------------------------------------------------------------------------
8944 dnl CF_WITH_ABI_VERSION version: 5 updated: 2023/01/07 16:32:06
8945 dnl -------------------
8946 dnl Allow library's ABI to be overridden.  Generally this happens when a
8947 dnl packager has incremented the ABI past that used in the original package,
8948 dnl and wishes to keep doing this.
8949 dnl
8950 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
8951 dnl symbol.
8952 AC_DEFUN([CF_WITH_ABI_VERSION],[
8953 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
8954 AC_ARG_WITH(abi-version,
8955 [  --with-abi-version=XXX  override derived ABI version],[
8956         if test "x$cf_cv_abi_version" != "x$withval"
8957         then
8958                 AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
8959                 case "$cf_cv_rel_version" in
8960                 (5.*)
8961                         cf_cv_rel_version=$withval.0
8962                         ;;
8963                 (6.*)
8964                         cf_cv_rel_version=$withval.9    # FIXME: should be 10 as of 6.0 release
8965                         ;;
8966                 esac
8967         fi
8968         cf_cv_abi_version=$withval])
8969         CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
8970 ifelse($1,,,[
8971 $1_ABI=$cf_cv_abi_version
8972 ])
8973 cf_cv_abi_default=$cf_cv_abi_version
8974 ])dnl
8975 dnl ---------------------------------------------------------------------------
8976 dnl CF_WITH_ADA_COMPILER version: 3 updated: 2023/10/28 11:59:01
8977 dnl --------------------
8978 dnl Command-line option to specify the Ada95 compiler.
8979 AC_DEFUN([CF_WITH_ADA_COMPILER],[
8980 AC_MSG_CHECKING(for Ada95 compiler)
8981 AC_ARG_WITH(ada-compiler,
8982         [[  --with-ada-compiler[=CMD] use CMD as Ada95 compiler (default: gnatmake)]],
8983         [cf_ada_compiler=$withval],
8984         [cf_ada_compiler=gnatmake])
8985 AC_SUBST(cf_ada_compiler)
8986 AC_MSG_RESULT($cf_ada_compiler)
8987 ])dnl
8988 dnl ---------------------------------------------------------------------------
8989 dnl CF_WITH_ADA_INCLUDE version: 3 updated: 2023/10/28 11:59:01
8990 dnl -------------------
8991 dnl Command-line option to specify where Ada includes will install.
8992 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
8993 AC_MSG_CHECKING(for Ada95 include directory)
8994 CF_WITH_PATH(ada-include,
8995    [  --with-ada-include=DIR  find Ada95 includes in DIR],
8996    ADA_INCLUDE,
8997    PREFIX/share/ada/adainclude,
8998    [$]prefix/share/ada/adainclude)
8999 AC_SUBST(ADA_INCLUDE)
9000 AC_MSG_RESULT($ADA_INCLUDE)
9001 ])dnl
9002 dnl ---------------------------------------------------------------------------
9003 dnl CF_WITH_ADA_LIBNAME version: 3 updated: 2023/11/22 20:48:30
9004 dnl -------------------
9005 dnl CF_WITH_ADA_LIBNAME
9006 dnl -------------------
9007 dnl Command-line option to specify how to name the resulting Ada library.
9008 dnl $1 = default value
9009 AC_DEFUN([CF_WITH_ADA_LIBNAME],[
9010 AC_MSG_CHECKING(for Ada95 curses library name)
9011 AC_ARG_WITH(ada-libname,
9012    [[  --with-ada-libname[=XXX]  use XXX as Ada95 library name]],
9013    ADA_LIBNAME=[$]withval,
9014    ADA_LIBNAME=$1)
9015 case "x$ADA_LIBNAME" in
9016 (x|xyes|xno)
9017         ADA_LIBNAME=$1
9018         ;;
9019 esac
9020 AC_SUBST(ADA_LIBNAME)
9021 AC_MSG_RESULT($ADA_LIBNAME)
9022 ])dnl
9023 dnl ---------------------------------------------------------------------------
9024 dnl CF_WITH_ADA_OBJECTS version: 3 updated: 2023/10/28 11:59:01
9025 dnl -------------------
9026 dnl Command-line option to specify where Ada objects will install.
9027 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
9028 AC_MSG_CHECKING(for Ada95 object directory)
9029 CF_WITH_PATH(ada-objects,
9030    [  --with-ada-objects=DIR  find Ada95 objects in DIR],
9031    ADA_OBJECTS,
9032    PREFIX/lib/ada/adalib,
9033    [$]prefix/lib/ada/adalib)
9034 AC_SUBST(ADA_OBJECTS)
9035 AC_MSG_RESULT($ADA_OBJECTS)
9036 ])dnl
9037 dnl ---------------------------------------------------------------------------
9038 dnl CF_WITH_ADA_SHAREDLIB version: 6 updated: 2023/10/28 11:59:01
9039 dnl ---------------------
9040 dnl Command-line option to specify if an Ada95 shared library should be built,
9041 dnl and optionally what its soname should be.
9042 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
9043 AC_REQUIRE([CF_GNAT_PROJECTS])
9044 AC_MSG_CHECKING(whether to build an Ada95 shared library)
9045 AC_ARG_WITH(ada-sharedlib,
9046         [  --with-ada-sharedlib    build Ada95 shared library; requires GNAT project support],
9047         [with_ada_sharedlib=$withval],
9048         [with_ada_sharedlib=no])
9049 cf_ada_sharedlib_warn=no
9050
9051 if test "x$with_ada_sharedlib" != xno
9052 then
9053         if test "x$cf_gnat_projects" != xyes
9054         then
9055                 with_ada_sharedlib=no
9056                 cf_ada_sharedlib_warn=yes
9057         fi
9058 fi
9059
9060 AC_MSG_RESULT($with_ada_sharedlib)
9061 if test "x$cf_ada_sharedlib_warn" != xno
9062 then
9063         AC_MSG_WARN(disabling Ada95 shared library since GNAT projects are not supported)
9064 fi
9065
9066 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
9067 MAKE_ADA_SHAREDLIB="#"
9068
9069 if test "x$with_ada_sharedlib" != xno
9070 then
9071         MAKE_ADA_SHAREDLIB=
9072         if test "x$with_ada_sharedlib" != xyes
9073         then
9074                 ADA_SHAREDLIB="$with_ada_sharedlib"
9075         fi
9076 fi
9077
9078 AC_SUBST(ADA_SHAREDLIB)
9079 AC_SUBST(MAKE_ADA_SHAREDLIB)
9080 ])dnl
9081 dnl ---------------------------------------------------------------------------
9082 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
9083 dnl ----------------
9084 dnl Configure-option for dbmalloc.  The optional parameter is used to override
9085 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
9086 AC_DEFUN([CF_WITH_DBMALLOC],[
9087 CF_NO_LEAKS_OPTION(dbmalloc,
9088         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
9089         [USE_DBMALLOC])
9090
9091 if test "$with_dbmalloc" = yes ; then
9092         AC_CHECK_HEADER(dbmalloc.h,
9093                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
9094 fi
9095 ])dnl
9096 dnl ---------------------------------------------------------------------------
9097 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
9098 dnl ---------------
9099 dnl Configure-option for dmalloc.  The optional parameter is used to override
9100 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
9101 AC_DEFUN([CF_WITH_DMALLOC],[
9102 CF_NO_LEAKS_OPTION(dmalloc,
9103         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
9104         [USE_DMALLOC])
9105
9106 if test "$with_dmalloc" = yes ; then
9107         AC_CHECK_HEADER(dmalloc.h,
9108                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
9109 fi
9110 ])dnl
9111 dnl ---------------------------------------------------------------------------
9112 dnl CF_WITH_EXPORT_SYMS version: 5 updated: 2023/11/22 20:48:30
9113 dnl -------------------
9114 dnl Use this with libtool to specify the list of symbols that may be exported.
9115 dnl The input file contains one symbol per line; comments work with "#".
9116 dnl
9117 dnl $1 = basename of the ".sym" file (default $PACKAGE)
9118 AC_DEFUN([CF_WITH_EXPORT_SYMS],
9119 [
9120 AC_MSG_CHECKING(if exported-symbols file should be used)
9121 AC_ARG_WITH(export-syms,
9122         [[  --with-export-syms[=SYM-FILE] limit symbols exported by libtool to those listed in SYM-FILE]],
9123         [with_export_syms=$withval],
9124         [with_export_syms=no])
9125 if test "x$with_export_syms" = xyes
9126 then
9127         with_export_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).sym'
9128         AC_SUBST(PACKAGE)
9129 fi
9130 AC_MSG_RESULT($with_export_syms)
9131 if test "x$with_export_syms" != xno
9132 then
9133         EXPORT_SYMS="-export-symbols $with_export_syms"
9134         AC_SUBST(EXPORT_SYMS)
9135 fi
9136 ])dnl
9137 dnl ---------------------------------------------------------------------------
9138 dnl CF_WITH_GPM version: 10 updated: 2017/04/29 18:32:18
9139 dnl -----------
9140 dnl
9141 dnl The option parameter (if neither yes/no) is assumed to be the name of
9142 dnl the gpm library, e.g., for dynamic loading.
9143 AC_DEFUN([CF_WITH_GPM],
9144 [
9145 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
9146 AC_ARG_WITH(gpm,
9147         [  --with-gpm              use Alessandro Rubini's GPM library],
9148         [with_gpm=$withval],
9149         [with_gpm=maybe])
9150 AC_MSG_RESULT($with_gpm)
9151
9152 if test "$with_gpm" != no ; then
9153         AC_CHECK_HEADER(gpm.h,[
9154                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
9155                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
9156                         CF_VERBOSE(assuming we really have GPM library)
9157                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
9158                         with_gpm=yes
9159                 else
9160                         AC_CHECK_LIB(gpm,Gpm_Open,[with_gpm=yes],[
9161                                 if test "$with_gpm" = maybe; then
9162                                         AC_MSG_WARN(Cannot link with GPM library)
9163                                         with_gpm=no
9164                                 else
9165                                         AC_MSG_ERROR(Cannot link with GPM library)
9166                                 fi
9167                         ])
9168                 fi
9169         ],[
9170                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
9171                 with_gpm=no
9172         ])
9173 fi
9174 ])
9175 dnl ---------------------------------------------------------------------------
9176 dnl CF_WITH_LIBTOOL version: 36 updated: 2021/01/01 13:31:04
9177 dnl ---------------
9178 dnl Provide a configure option to incorporate libtool.  Define several useful
9179 dnl symbols for the makefile rules.
9180 dnl
9181 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
9182 dnl macros from libtool.m4 which is in the aclocal directory of automake.
9183 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
9184 dnl But that still does not work properly since the macro is expanded outside
9185 dnl the CF_WITH_LIBTOOL macro:
9186 dnl
9187 dnl     #!/bin/sh
9188 dnl     ACLOCAL=`aclocal --print-ac-dir`
9189 dnl     if test -z "$ACLOCAL" ; then
9190 dnl             echo cannot find aclocal directory
9191 dnl             exit 1
9192 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
9193 dnl             echo cannot find libtool.m4 file
9194 dnl             exit 1
9195 dnl     fi
9196 dnl
9197 dnl     LOCAL=aclocal.m4
9198 dnl     ORIG=aclocal.m4.orig
9199 dnl
9200 dnl     trap "mv $ORIG $LOCAL" 0 1 2 3 15
9201 dnl     rm -f $ORIG
9202 dnl     mv $LOCAL $ORIG
9203 dnl
9204 dnl     # sed the LIBTOOL= assignment to omit the current directory?
9205 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
9206 dnl     cat $ORIG >>$LOCAL
9207 dnl
9208 dnl     autoconf-257 $*
9209 dnl
9210 AC_DEFUN([CF_WITH_LIBTOOL],
9211 [
9212 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
9213 ifdef([AC_PROG_LIBTOOL],,[
9214 LIBTOOL=
9215 ])
9216 # common library maintenance symbols that are convenient for libtool scripts:
9217 LIB_CREATE='${AR} -cr'
9218 LIB_OBJECT='${OBJECTS}'
9219 LIB_SUFFIX=.a
9220 LIB_PREP="$RANLIB"
9221
9222 # symbols used to prop libtool up to enable it to determine what it should be
9223 # doing:
9224 LIB_CLEAN=
9225 LIB_COMPILE=
9226 LIB_LINK='${CC}'
9227 LIB_INSTALL=
9228 LIB_UNINSTALL=
9229
9230 AC_MSG_CHECKING(if you want to build libraries with libtool)
9231 AC_ARG_WITH(libtool,
9232         [  --with-libtool          generate libraries with libtool],
9233         [with_libtool=$withval],
9234         [with_libtool=no])
9235 AC_MSG_RESULT($with_libtool)
9236 if test "$with_libtool" != "no"; then
9237 ifdef([AC_PROG_LIBTOOL],[
9238         # missing_content_AC_PROG_LIBTOOL{{
9239         AC_PROG_LIBTOOL
9240         # missing_content_AC_PROG_LIBTOOL}}
9241 ],[
9242         if test "$with_libtool" != "yes" ; then
9243                 CF_PATH_SYNTAX(with_libtool)
9244                 LIBTOOL=$with_libtool
9245         else
9246                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
9247                 CF_LIBTOOL_VERSION
9248                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
9249                 then
9250                         CF_FORGET_TOOL(LIBTOOL)
9251                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
9252                         CF_LIBTOOL_VERSION
9253                 fi
9254         fi
9255         if test -z "$LIBTOOL" ; then
9256                 AC_MSG_ERROR(Cannot find libtool)
9257         fi
9258 ])dnl
9259         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${libdir} ${LIBTOOL_VERSION} `cut -f1 ${top_srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
9260         LIB_OBJECT='${OBJECTS:.o=.lo}'
9261         LIB_SUFFIX=.la
9262         LIB_CLEAN='${LIBTOOL} --mode=clean'
9263         LIB_COMPILE='${LIBTOOL} --mode=compile'
9264         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
9265         LIB_INSTALL='${LIBTOOL} --mode=install'
9266         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
9267         LIB_PREP=:
9268
9269         CF_CHECK_LIBTOOL_VERSION
9270
9271         # special hack to add -no-undefined (which libtool should do for itself)
9272         LT_UNDEF=
9273         case "$cf_cv_system_name" in
9274         (cygwin*|msys*|mingw32*|os2*|uwin*|aix[[4-7]])
9275                 LT_UNDEF=-no-undefined
9276                 ;;
9277         esac
9278         AC_SUBST([LT_UNDEF])
9279
9280         # special hack to add --tag option for C++ compiler
9281         case "$cf_cv_libtool_version" in
9282         (1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*)
9283                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
9284                 LIBTOOL="$LIBTOOL --tag=CC"
9285                 ;;
9286         (*)
9287                 LIBTOOL_CXX="$LIBTOOL"
9288                 ;;
9289         esac
9290 else
9291         LIBTOOL=""
9292         LIBTOOL_CXX=""
9293 fi
9294
9295 test -z "$LIBTOOL" && ECHO_LT=
9296
9297 AC_SUBST(LIBTOOL)
9298 AC_SUBST(LIBTOOL_CXX)
9299 AC_SUBST(LIBTOOL_OPTS)
9300
9301 AC_SUBST(LIB_CREATE)
9302 AC_SUBST(LIB_OBJECT)
9303 AC_SUBST(LIB_SUFFIX)
9304 AC_SUBST(LIB_PREP)
9305
9306 AC_SUBST(LIB_CLEAN)
9307 AC_SUBST(LIB_COMPILE)
9308 AC_SUBST(LIB_LINK)
9309 AC_SUBST(LIB_INSTALL)
9310 AC_SUBST(LIB_UNINSTALL)
9311
9312 ])dnl
9313 dnl ---------------------------------------------------------------------------
9314 dnl CF_WITH_LIBTOOL_OPTS version: 6 updated: 2023/11/22 20:48:30
9315 dnl --------------------
9316 dnl Allow user to pass additional libtool options into the library creation
9317 dnl and link steps.  The main use for this is to do something like
9318 dnl     ./configure --with-libtool-opts=-static
9319 dnl to get the same behavior as automake-flavored
9320 dnl     ./configure --enable-static
9321 AC_DEFUN([CF_WITH_LIBTOOL_OPTS],[
9322 AC_MSG_CHECKING(for additional libtool options)
9323 AC_ARG_WITH(libtool-opts,
9324         [[  --with-libtool-opts[=XXX] give libtool additional options XXX]],
9325         [with_libtool_opts=$withval],
9326         [with_libtool_opts=no])
9327 AC_MSG_RESULT($with_libtool_opts)
9328
9329 case .$with_libtool_opts in
9330 (.yes|.no|.)
9331         ;;
9332 (*)
9333         LIBTOOL_OPTS="$LIBTOOL_OPTS $with_libtool_opts"
9334         ;;
9335 esac
9336
9337 AC_SUBST(LIBTOOL_OPTS)
9338 ])dnl
9339 dnl ---------------------------------------------------------------------------
9340 dnl CF_WITH_LIB_BASENAME version: 2 updated: 2023/11/22 20:48:30
9341 dnl --------------------
9342 dnl Allow for overriding the basename of a library, i.e., the part to which
9343 dnl prefixes/suffixes are attached.
9344 dnl
9345 dnl $1 = variable to set
9346 dnl $2 = option name
9347 dnl $3 = default basename for library, if omitted use $2
9348 AC_DEFUN([CF_WITH_LIB_BASENAME],
9349 [
9350 AC_MSG_CHECKING(for desired basename for $2 library)
9351 AC_ARG_WITH($2-libname,
9352         [[  --with-$2-libname[=XXX] override ifelse($3,,$2,$3) basename of library]],
9353         [with_lib_basename=$withval],
9354         [with_lib_basename=ifelse($3,,$2,$3)])
9355 $1="$with_lib_basename"
9356
9357 case "x[$]$1" in
9358 (x|xno|xnone|xyes)
9359         $1=ifelse($3,,$2,$3)
9360         ;;
9361 (*)
9362         ;;
9363 esac
9364
9365 AC_MSG_RESULT([$]$1)
9366 AC_SUBST($1)
9367 ])dnl
9368 dnl ---------------------------------------------------------------------------
9369 dnl CF_WITH_LIB_PREFIX version: 2 updated: 2021/01/01 16:53:59
9370 dnl ------------------
9371 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
9372 dnl "lib" prefix, e.g., because it used the dll naming convention.
9373 dnl
9374 dnl $1 = variable to set
9375 AC_DEFUN([CF_WITH_LIB_PREFIX],
9376 [
9377 AC_MSG_CHECKING(if you want to have a library-prefix)
9378 AC_ARG_WITH(lib-prefix,
9379         [  --with-lib-prefix       override library-prefix],
9380         [with_lib_prefix=$withval],
9381         [with_lib_prefix=auto])
9382 AC_MSG_RESULT($with_lib_prefix)
9383
9384 if test "$with_lib_prefix" = auto
9385 then
9386         CF_LIB_PREFIX($1)
9387 elif test "$with_lib_prefix" = no
9388 then
9389         LIB_PREFIX=
9390 else
9391         LIB_PREFIX=$with_lib_prefix
9392 fi
9393 ])dnl
9394 dnl ---------------------------------------------------------------------------
9395 dnl CF_WITH_PATH version: 12 updated: 2021/09/04 06:35:04
9396 dnl ------------
9397 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
9398 dnl defaulting to yes/no.
9399 dnl
9400 dnl $1 = option name
9401 dnl $2 = help-text
9402 dnl $3 = environment variable to set
9403 dnl $4 = default value, shown in the help-message, must be a constant
9404 dnl $5 = default value, if it is an expression & cannot be in the help-message
9405 dnl
9406 AC_DEFUN([CF_WITH_PATH],
9407 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
9408 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
9409 if ifelse([$5],,true,[test -n "$5"]) ; then
9410 CF_PATH_SYNTAX(withval)
9411 fi
9412 eval $3="$withval"
9413 AC_SUBST($3)dnl
9414 ])dnl
9415 dnl ---------------------------------------------------------------------------
9416 dnl CF_WITH_PATHLIST version: 13 updated: 2021/09/04 06:35:04
9417 dnl ----------------
9418 dnl Process an option specifying a list of colon-separated paths.
9419 dnl
9420 dnl $1 = option name
9421 dnl $2 = help-text
9422 dnl $3 = environment variable to set
9423 dnl $4 = default value, shown in the help-message, must be a constant
9424 dnl $5 = default value, if it is an expression & cannot be in the help-message
9425 dnl $6 = flag to tell if we want to define or substitute
9426 dnl
9427 AC_DEFUN([CF_WITH_PATHLIST],[
9428 AC_REQUIRE([CF_PATHSEP])
9429 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
9430 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
9431
9432 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
9433 cf_dst_path=
9434 for cf_src_path in $withval
9435 do
9436   CF_PATH_SYNTAX(cf_src_path)
9437   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
9438   cf_dst_path="${cf_dst_path}${cf_src_path}"
9439 done
9440 IFS="$ac_save_ifs"
9441
9442 ifelse($6,define,[
9443 # Strip single quotes from the value, e.g., when it was supplied as a literal
9444 # for $4 or $5.
9445 case "$cf_dst_path" in
9446 (\'*)
9447   cf_dst_path="`echo "$cf_dst_path" |sed -e s/\'// -e s/\'\$//`"
9448   ;;
9449 esac
9450 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
9451 ])
9452
9453 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
9454 # so we have to check/work around.  We do prefer the result of "eval"...
9455 eval cf_dst_eval="$cf_dst_path"
9456 case "x$cf_dst_eval" in
9457 (xNONE*)
9458         $3=$cf_dst_path
9459         ;;
9460 (*)
9461         $3="$cf_dst_eval"
9462         ;;
9463 esac
9464 AC_SUBST($3)dnl
9465
9466 ])dnl
9467 dnl ---------------------------------------------------------------------------
9468 dnl CF_WITH_PATH_PROG version: 1 updated: 2019/06/30 19:44:43
9469 dnl -----------------
9470 dnl Check for a given program, like CF_PATH_PROG, but allow override using a
9471 dnl "--with-xxx" option.
9472 dnl
9473 dnl Parameters:
9474 dnl             $1 = environment variable to set/update
9475 dnl             $2 = program name
9476 dnl             $3 = help-text
9477 dnl             $4 = $PATH
9478 AC_DEFUN([CF_WITH_PATH_PROG],[
9479 AC_ARG_WITH($2-path,
9480         [  --with-$2-path=XXX     specify path of $2 ifelse($3,,,$3)],
9481         [AC_MSG_CHECKING(for $2 program ifelse($3,,,$3))
9482                 $1=$withval
9483                 AC_MSG_RESULT([$]$1)
9484                 CF_PATH_SYNTAX($1)
9485         ],
9486         [CF_PATH_PROG($1,$2,,ifelse($4,,,$4))
9487                 if test -z "[$]$1"
9488                 then
9489                         AC_MSG_WARN(no $2 program found ifelse($3,,,$3))
9490                 fi
9491         ])
9492 ])
9493 dnl ---------------------------------------------------------------------------
9494 dnl CF_WITH_PCRE2 version: 6 updated: 2021/08/11 20:35:34
9495 dnl -------------
9496 dnl Add PCRE2 (Perl-compatible regular expressions v2) to the build if it is
9497 dnl available and the user requests it.  Assume the application will otherwise
9498 dnl use the POSIX interface.
9499 dnl
9500 dnl TODO allow $withval to specify package location
9501 AC_DEFUN([CF_WITH_PCRE2],
9502 [
9503 AC_REQUIRE([CF_PKG_CONFIG])
9504
9505 AC_MSG_CHECKING(if you want to use PCRE2 for regular-expressions)
9506 AC_ARG_WITH(pcre2,
9507         [  --with-pcre2            use PCRE2 for regular-expressions])
9508 test -z "$with_pcre2" && with_pcre2=no
9509 AC_MSG_RESULT($with_pcre2)
9510
9511 if test "x$with_pcre2" != xno ; then
9512         cf_with_pcre2_ok=no
9513         for cf_with_pcre2 in libpcre2 libpcre2-posix libpcre
9514         do
9515                 CF_TRY_PKG_CONFIG($cf_with_pcre2,[cf_with_pcre2_ok=yes; break])
9516         done
9517         cf_with_pcre2_ok=yes || AC_MSG_ERROR(Cannot find PCRE2 library)
9518
9519         AC_DEFINE(HAVE_LIB_PCRE2,1,[Define to 1 if we can/should compile with the PCRE2 library])
9520
9521         # if pkgconfig gave no results, look for the libraries directly
9522         case "$LIBS" in
9523         (*pcre2-posix*|*pcreposix*)
9524                 ;;
9525         (*)
9526                 AC_CHECK_LIB(pcre2-posix,regcomp,[
9527                         CF_ADD_LIB(pcre2-posix)],
9528                         [AC_CHECK_LIB(pcreposix,regcomp,[
9529                          CF_ADD_LIB(pcreposix)
9530                         ],[AC_MSG_ERROR(Cannot find PCRE2 POSIX library)])])
9531                 ;;
9532         esac
9533
9534         # either way, check for the library header files
9535         AC_CHECK_HEADERS(pcre2posix.h pcreposix.h)
9536         AC_CHECK_FUNCS(PCRE2regcomp)
9537 fi
9538 ])dnl
9539 dnl ---------------------------------------------------------------------------
9540 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 23 updated: 2023/11/22 20:48:30
9541 dnl -------------------------
9542 dnl Allow the choice of the pkg-config library directory to be overridden.
9543 dnl
9544 dnl pkg-config uses a search-list built from these colon-separated lists of
9545 dnl directories:
9546 dnl a) $PKG_CONFIG_PATH (tested first, added if set)
9547 dnl b) $PKG_CONFIG_LIBDIR (tested second, added if set)
9548 dnl c) builtin-list (added if $PKG_CONFIG_LIBDIR is not set)
9549 dnl
9550 dnl pkgconf (used with some systems such as FreeBSD in place of pkg-config)
9551 dnl optionally ignores $PKG_CONFIG_LIBDIR.  Very old versions of pkg-config,
9552 dnl e.g., Solaris 10 also do not recognize $PKG_CONFIG_LIBDIR.
9553 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
9554
9555 case "$PKG_CONFIG" in
9556 (no|none|yes)
9557         AC_MSG_CHECKING(for pkg-config library directory)
9558         ;;
9559 (*)
9560         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
9561         ;;
9562 esac
9563
9564 # if $PKG_CONFIG_LIBDIR is set, try to use that
9565 if test -n "$PKG_CONFIG_PATH"; then
9566         cf_search_path=`echo "$PKG_CONFIG_PATH" | sed -e 's/:/ /g' -e 's,^[[    ]]*,,' -e 's,[[         ]]*$,,'`
9567 elif test -n "$PKG_CONFIG_LIBDIR"; then
9568         cf_search_path=`echo "$PKG_CONFIG_LIBDIR" | sed -e 's/:/ /g' -e 's,^[[  ]]*,,' -e 's,[[         ]]*$,,'`
9569 else
9570         cf_search_path=auto
9571 fi
9572
9573 # if the option is used, let that override.  otherwise default to "libdir"
9574 AC_ARG_WITH(pkg-config-libdir,
9575         [[  --with-pkg-config-libdir[=XXX] use given directory for installing pc-files]],
9576         [cf_search_path=$withval],
9577         [test "x$PKG_CONFIG" != xnone && test -z "$cf_search_path" && cf_search_path=libdir])
9578
9579 case "x$cf_search_path" in
9580 (xlibdir)
9581         PKG_CONFIG_LIBDIR='${libdir}/pkgconfig'
9582         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
9583         cf_search_path=
9584         ;;
9585 (x)
9586         ;;
9587 (x/*\ *)
9588         PKG_CONFIG_LIBDIR=
9589         ;;
9590 (x/*)
9591         PKG_CONFIG_LIBDIR="$cf_search_path"
9592         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
9593         cf_search_path=
9594         ;;
9595 (xyes|xauto)
9596         AC_MSG_RESULT(auto)
9597         cf_search_path=
9598         # Look for the library directory using the same prefix as the executable
9599         AC_MSG_CHECKING(for search-list)
9600         if test "x$PKG_CONFIG" != xnone
9601         then
9602                 # works for pkg-config since version 0.24 (2009)
9603                 # works for pkgconf since version 0.8.3 (2012)
9604                 for cf_pkg_program in \
9605                         `echo "$PKG_CONFIG" | sed -e 's,^.*/,,'` \
9606                         pkg-config \
9607                         pkgconf
9608                 do
9609                         cf_search_path=`"$PKG_CONFIG" --variable=pc_path "$cf_pkg_program" 2>/dev/null | tr : ' '`
9610                         test -n "$cf_search_path" && break
9611                 done
9612
9613                 # works for pkg-config since import in 2005 of original 2001 HP code.
9614                 test -z "$cf_search_path" && \
9615                 cf_search_path=`
9616                 "$PKG_CONFIG" --debug --exists no-such-package 2>&1 | $AWK "\
9617 /^Scanning directory (#[1-9][0-9]* )?'.*'$/{ \
9618         sub(\"^[[^']]*'\",\"\"); \
9619         sub(\"'.*\",\"\"); \
9620         printf \" %s\", \\[$]0; } \
9621 { next; } \
9622 "`
9623         fi
9624
9625         AC_MSG_RESULT($cf_search_path)
9626         ;;
9627 (*)
9628         AC_MSG_ERROR(Unexpected option value: $cf_search_path)
9629         ;;
9630 esac
9631
9632 if test -n "$cf_search_path"
9633 then
9634         AC_MSG_CHECKING(for first directory)
9635         cf_pkg_config_path=none
9636         for cf_config in $cf_search_path
9637         do
9638                 if test -d "$cf_config"
9639                 then
9640                         cf_pkg_config_path=$cf_config
9641                         break
9642                 fi
9643         done
9644         AC_MSG_RESULT($cf_pkg_config_path)
9645
9646         if test "x$cf_pkg_config_path" != xnone ; then
9647                 # limit this to the first directory found
9648                 PKG_CONFIG_LIBDIR="$cf_pkg_config_path"
9649         fi
9650
9651         if test -z "$PKG_CONFIG_LIBDIR" && test -n "$cf_search_path"
9652         then
9653                 AC_MSG_CHECKING(for workaround)
9654                 if test "$prefix" = "NONE" ; then
9655                         cf_prefix="$ac_default_prefix"
9656                 else
9657                         cf_prefix="$prefix"
9658                 fi
9659                 eval cf_libdir=$libdir
9660                 cf_libdir=`echo "$cf_libdir" | sed -e "s,^NONE,$cf_prefix,"`
9661                 cf_backup=
9662                 for cf_config in $cf_search_path
9663                 do
9664                         case $cf_config in
9665                         $cf_libdir/pkgconfig)
9666                                 PKG_CONFIG_LIBDIR=$cf_libdir/pkgconfig
9667                                 break
9668                                 ;;
9669                         *)
9670                                 test -z "$cf_backup" && cf_backup=$cf_config
9671                                 ;;
9672                         esac
9673                 done
9674                 test -z "$PKG_CONFIG_LIBDIR" && PKG_CONFIG_LIBDIR=$cf_backup
9675                 AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
9676         fi
9677 fi
9678
9679 AC_SUBST(PKG_CONFIG_LIBDIR)
9680 ])dnl
9681 dnl ---------------------------------------------------------------------------
9682 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
9683 dnl ---------------
9684 dnl Check for POSIX thread library.
9685 AC_DEFUN([CF_WITH_PTHREAD],
9686 [
9687 AC_MSG_CHECKING(if you want to link with the pthread library)
9688 AC_ARG_WITH(pthread,
9689         [  --with-pthread          use POSIX thread library],
9690         [with_pthread=$withval],
9691         [with_pthread=no])
9692 AC_MSG_RESULT($with_pthread)
9693
9694 if test "$with_pthread" != no ; then
9695         AC_CHECK_HEADER(pthread.h,[
9696         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
9697
9698         for cf_lib_pthread in pthread c_r
9699         do
9700             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
9701             cf_save_LIBS="$LIBS"
9702             CF_ADD_LIB($cf_lib_pthread)
9703             AC_TRY_LINK([
9704 #include <pthread.h>
9705 ],[
9706                 int rc = pthread_create(0,0,0,0);
9707                 int r2 = pthread_mutexattr_settype(0, 0);
9708 ],[with_pthread=yes],[with_pthread=no])
9709             LIBS="$cf_save_LIBS"
9710             AC_MSG_RESULT($with_pthread)
9711             test "$with_pthread" = yes && break
9712         done
9713
9714         if test "$with_pthread" = yes ; then
9715             CF_ADD_LIB($cf_lib_pthread)
9716             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
9717         else
9718             AC_MSG_ERROR(Cannot link with pthread library)
9719         fi
9720         ])
9721 fi
9722 ])
9723 dnl ---------------------------------------------------------------------------
9724 dnl CF_WITH_REL_VERSION version: 2 updated: 2023/05/06 18:18:18
9725 dnl -------------------
9726 dnl Allow library's release-version to be overridden.  Generally this happens when a
9727 dnl packager has incremented the release-version past that used in the original package,
9728 dnl and wishes to keep doing this.
9729 dnl
9730 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
9731 dnl and {package}_MINOR symbols
9732 dnl symbol.
9733 AC_DEFUN([CF_WITH_REL_VERSION],[
9734 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
9735 AC_ARG_WITH(rel-version,
9736 [  --with-rel-version=XXX  override derived release version],
9737 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
9738  cf_cv_rel_version=$withval])
9739 ifelse($1,,[
9740  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
9741 ],[
9742  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
9743  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
9744  test -n "$1_MINOR" || $1_MINOR=0
9745  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
9746  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
9747 ])
9748 ])dnl
9749 dnl ---------------------------------------------------------------------------
9750 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
9751 dnl ----------------
9752 dnl If we can compile with sysmouse, make it available unless it is not wanted.
9753 AC_DEFUN([CF_WITH_SYSMOUSE],[
9754 # not everyone has "test -c"
9755 if test -c /dev/sysmouse 2>/dev/null ; then
9756 AC_MSG_CHECKING(if you want to use sysmouse)
9757 AC_ARG_WITH(sysmouse,
9758         [  --with-sysmouse         use sysmouse (FreeBSD console)],
9759         [cf_with_sysmouse=$withval],
9760         [cf_with_sysmouse=maybe])
9761         if test "$cf_with_sysmouse" != no ; then
9762         AC_TRY_COMPILE([
9763 #include <osreldate.h>
9764 #if (__FreeBSD_version >= 400017)
9765 #include <sys/consio.h>
9766 #include <sys/fbio.h>
9767 #else
9768 #include <machine/console.h>
9769 #endif
9770 ],[
9771         struct mouse_info the_mouse;
9772         ioctl(0, CONS_MOUSECTL, &the_mouse);
9773 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
9774         fi
9775 AC_MSG_RESULT($cf_with_sysmouse)
9776 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
9777 fi
9778 ])dnl
9779 dnl ---------------------------------------------------------------------------
9780 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
9781 dnl ---------------
9782 dnl For testing, override the derived host system-type which is used to decide
9783 dnl things such as the linker commands used to build shared libraries.  This is
9784 dnl normally chosen automatically based on the type of system which you are
9785 dnl building on.  We use it for testing the configure script.
9786 dnl
9787 dnl This is different from the --host option: it is used only for testing parts
9788 dnl of the configure script which would not be reachable with --host since that
9789 dnl relies on the build environment being real, rather than mocked up.
9790 AC_DEFUN([CF_WITH_SYSTYPE],[
9791 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
9792 AC_ARG_WITH(system-type,
9793         [  --with-system-type=XXX  test: override derived host system-type],
9794 [AC_MSG_WARN(overriding system type to $withval)
9795         cf_cv_system_name=$withval
9796         host_os=$withval
9797 ])
9798 ])dnl
9799 dnl ---------------------------------------------------------------------------
9800 dnl CF_WITH_TYPE version: 2 updated: 2023/11/25 16:11:47
9801 dnl ------------
9802 dnl Accept a TYPE for substitution:
9803 dnl $1 = name of type
9804 dnl $2 = help/usage message
9805 dnl $3 = symbol to set
9806 dnl $4 = default value
9807 AC_DEFUN([CF_WITH_TYPE],[
9808 AC_MSG_CHECKING(for type of $1)
9809 AC_ARG_WITH([$1], [$2],
9810         [$3="$withval"],
9811         [$3=$4])
9812 AC_MSG_RESULT([$]$3)
9813 case x[$]$3 in
9814 (x|xyes|xno)
9815         AC_MSG_ERROR(expected a type name for $1)
9816         ;;
9817 esac
9818 AC_SUBST($3)
9819 ])dnl
9820 dnl ---------------------------------------------------------------------------
9821 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
9822 dnl ----------------
9823 AC_DEFUN([CF_WITH_VALGRIND],[
9824 CF_NO_LEAKS_OPTION(valgrind,
9825         [  --with-valgrind         test: use valgrind],
9826         [USE_VALGRIND])
9827 ])dnl
9828 dnl ---------------------------------------------------------------------------
9829 dnl CF_WITH_VERSIONED_SYMS version: 13 updated: 2023/12/03 09:24:04
9830 dnl ----------------------
9831 dnl Use this when building shared library with ELF, to markup symbols with the
9832 dnl version identifier from the given input file.  Generally that identifier is
9833 dnl the same as the SONAME at which the symbol was first introduced.
9834 dnl
9835 dnl $1 = basename of the ".map" file (default $PACKAGE)
9836 AC_DEFUN([CF_WITH_VERSIONED_SYMS],
9837 [AC_REQUIRE([AC_PROG_FGREP])dnl
9838 AC_REQUIRE([AC_PROG_EGREP])dnl
9839
9840 AC_MSG_CHECKING(if versioned-symbols file should be used)
9841 AC_ARG_WITH(versioned-syms,
9842         [[  --with-versioned-syms[=MAP-FILE] version ELF shared library symbols per MAP-FILE]],
9843         [with_versioned_syms=$withval],
9844         [with_versioned_syms=no])
9845 case "x$with_versioned_syms" in
9846 (xyes)
9847         with_versioned_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).map'
9848         AC_SUBST(PACKAGE)
9849         ;;
9850 (xno)
9851         ;;
9852 (x/*)
9853         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
9854         ;;
9855 (*)
9856         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
9857         with_versioned_syms=`pwd`/"$with_versioned_syms"
9858         ;;
9859 esac
9860 AC_MSG_RESULT($with_versioned_syms)
9861
9862 RESULTING_SYMS=
9863 VERSIONED_SYMS=
9864 WILDCARD_SYMS=
9865
9866 if test "x$with_versioned_syms" != xno
9867 then
9868         RESULTING_SYMS=$with_versioned_syms
9869         case "x$MK_SHARED_LIB" in
9870         (*-Wl,*)
9871                 VERSIONED_SYMS="-Wl,--version-script,\${RESULTING_SYMS}"
9872                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-Wl,%\\[$]{VERSIONED_SYMS} -Wl,%"`
9873                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
9874                 ;;
9875         (*-dy\ *)
9876                 VERSIONED_SYMS="-Wl,-M,\${RESULTING_SYMS}"
9877                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-dy%\\[$]{VERSIONED_SYMS} -dy%"`
9878                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
9879                 ;;
9880         (*)
9881                 AC_MSG_WARN(this system does not support versioned-symbols)
9882                 ;;
9883         esac
9884
9885         # Linux ld can selectively override scope, e.g., of symbols beginning with
9886         # "_" by first declaring some as global, and then using a wildcard to
9887         # declare the others as local.  Some other loaders cannot do this.  Check
9888         # by constructing a (very) simple shared library and inspecting its
9889         # symbols.
9890         if test "x$VERSIONED_SYMS" != "x"
9891         then
9892                 AC_MSG_CHECKING(if wildcards can be used to selectively omit symbols)
9893                 WILDCARD_SYMS=no
9894
9895                 # make sources
9896                 rm -f conftest.*
9897
9898                 cat >conftest.ver <<EOF
9899 module_1.0 {
9900 global:
9901         globalf1;
9902 local:
9903         localf1;
9904 };
9905 module_2.0 {
9906 global:
9907         globalf2;
9908 local:
9909         localf2;
9910         _*;
9911 } module_1.0;
9912 submodule_1.0 {
9913 global:
9914         subglobalf1;
9915         _ismissing;
9916 local:
9917         sublocalf1;
9918 };
9919 submodule_2.0 {
9920 global:
9921         subglobalf2;
9922 local:
9923         sublocalf2;
9924         _*;
9925 } submodule_1.0;
9926 EOF
9927                 cat >conftest.$ac_ext <<EOF
9928 #line __oline__ "configure"
9929 extern int _ismissing(void);    int _ismissing(void)  { return 1; }
9930 extern int _localf1(void);      int _localf1(void)    { return 1; }
9931 extern int _localf2(void);      int _localf2(void)    { return 2; }
9932 extern int globalf1(void);      int globalf1(void)    { return 1; }
9933 extern int globalf2(void);      int globalf2(void)    { return 2; }
9934 extern int _sublocalf1(void);   int _sublocalf1(void) { return 1; }
9935 extern int _sublocalf2(void);   int _sublocalf2(void) { return 2; }
9936 extern int subglobalf1(void);   int subglobalf1(void) { return 1; }
9937 extern int subglobalf2(void);   int subglobalf2(void) { return 2; }
9938 EOF
9939                 cat >conftest.mk <<EOF
9940 CC=${CC}
9941 CFLAGS=${CFLAGS}
9942 CPPFLAGS=${CPPFLAGS}
9943 LDFLAGS=${LDFLAGS}
9944 LIBS=${LIBS}
9945 VERSIONED_SYMS=${VERSIONED_SYMS}
9946 RESULTING_SYMS=conftest.ver
9947 MK_SHARED_LIB=${MK_SHARED_LIB}
9948 conftest.so: conftest.$ac_cv_objext
9949                 \$(MK_SHARED_LIB) conftest.$ac_cv_objext
9950 EOF
9951
9952                 # compile source, make library
9953                 if make -f conftest.mk 2>&AC_FD_CC >/dev/null
9954                 then
9955                         # test for missing symbol in either Data or Text section
9956                         cf_missing="`nm -P conftest.so 2>&AC_FD_CC |${FGREP-fgrep} _ismissing | ${EGREP-egrep} '[[      ]][[DT]][[      ]]'`"
9957                         test -n "$cf_missing" && WILDCARD_SYMS=yes
9958                 fi
9959                 AC_MSG_RESULT($WILDCARD_SYMS)
9960                 rm -f conftest.*
9961         fi
9962 fi
9963 AC_SUBST(RESULTING_SYMS)
9964 AC_SUBST(VERSIONED_SYMS)
9965 AC_SUBST(WILDCARD_SYMS)
9966 ])dnl
9967 dnl ---------------------------------------------------------------------------
9968 dnl CF_WITH_X11_RGB version: 3 updated: 2023/10/28 11:59:01
9969 dnl ---------------
9970 dnl Handle configure option "--with-x11-rgb", setting these shell
9971 dnl variables:
9972 dnl
9973 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
9974 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
9975 dnl
9976 dnl Most Linux's use this:
9977 dnl     /usr/share/X11/rgb.txt
9978 dnl Debian uses this:
9979 dnl     /etc/X11/rgb.txt
9980 dnl DragonFlyBSD ports uses this:
9981 dnl     /usr/pkg/lib/X11/rgb.txt
9982 dnl FreeBSD ports use these:
9983 dnl     /usr/local/lib/X11/rgb.txt
9984 dnl     /usr/local/share/X11/rgb.txt
9985 dnl Mandriva has these:
9986 dnl     /usr/lib/X11/rgb.txt
9987 dnl     /usr/lib64/X11/rgb.txt
9988 dnl NetBSD has these
9989 dnl     /usr/X11R7/lib/X11/rgb.txt
9990 dnl OpenSolaris uses
9991 dnl     32-bit:
9992 dnl     /usr/X11/etc/X11/rgb.txt
9993 dnl     /usr/X11/share/X11/rgb.txt
9994 dnl     /usr/X11/lib/X11/rgb.txt
9995 dnl OSX uses
9996 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
9997 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
9998 dnl     64-bit:
9999 dnl     /usr/X11/etc/X11/rgb.txt
10000 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
10001 dnl     /usr/X11/lib/amd64/X11/rgb.txt
10002 dnl Solaris10 uses (in this order):
10003 dnl     /usr/openwin/lib/X11/rgb.txt
10004 dnl     /usr/X11/lib/X11/rgb.txt
10005 AC_DEFUN([CF_WITH_X11_RGB],[
10006 AC_MSG_CHECKING(for X11 rgb file)
10007 AC_ARG_WITH(x11-rgb,
10008         [  --with-x11-rgb=FILE     obtain X11 color definitions from FILE (default: EPREFIX/lib/X11/rgb.txt)],
10009         [RGB_PATH=$withval],
10010         [RGB_PATH=auto])
10011
10012 if test "x[$]RGB_PATH" = xauto
10013 then
10014         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
10015         for cf_path in \
10016                 /opt/local/share/X11/rgb.txt \
10017                 /opt/X11/share/X11/rgb.txt \
10018                 /usr/share/X11/rgb.txt \
10019                 /usr/X11/share/X11/rgb.txt \
10020                 /usr/X11/lib/X11/rgb.txt \
10021                 /usr/lib/X11/rgb.txt \
10022                 /etc/X11/rgb.txt \
10023                 /usr/pkg/lib/X11/rgb.txt \
10024                 /usr/X11R7/lib/X11/rgb.txt \
10025                 /usr/X11R6/lib/X11/rgb.txt \
10026                 /usr/X11R5/lib/X11/rgb.txt \
10027                 /usr/X11R4/lib/X11/rgb.txt \
10028                 /usr/local/lib/X11/rgb.txt \
10029                 /usr/local/share/X11/rgb.txt \
10030                 /usr/lib64/X11/rgb.txt
10031         do
10032                 if test -f "$cf_path" ; then
10033                         RGB_PATH="$cf_path"
10034                         break
10035                 fi
10036         done
10037 else
10038         cf_path=$RGB_PATH
10039         CF_PATH_SYNTAX(cf_path)
10040 fi
10041
10042 AC_MSG_RESULT($RGB_PATH)
10043 AC_SUBST(RGB_PATH)
10044 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path",[Define to the full pathname of rgb.txt])
10045
10046 no_x11_rgb=
10047 if test "$RGB_PATH" = no
10048 then
10049         no_x11_rgb="#"
10050 fi
10051 AC_SUBST(no_x11_rgb)
10052 ])dnl
10053 dnl ---------------------------------------------------------------------------
10054 dnl CF_XOPEN_SOURCE version: 67 updated: 2023/09/06 18:55:27
10055 dnl ---------------
10056 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
10057 dnl or adapt to the vendor's definitions to get equivalent functionality,
10058 dnl without losing the common non-POSIX features.
10059 dnl
10060 dnl Parameters:
10061 dnl     $1 is the nominal value for _XOPEN_SOURCE
10062 dnl     $2 is the nominal value for _POSIX_C_SOURCE
10063 dnl
10064 dnl The default case prefers _XOPEN_SOURCE over _POSIX_C_SOURCE if the
10065 dnl implementation predefines it, because X/Open and most implementations agree
10066 dnl that the latter is a legacy or "aligned" value.
10067 dnl
10068 dnl Because _XOPEN_SOURCE is preferred, if defining _POSIX_C_SOURCE turns
10069 dnl that off, then refrain from setting _POSIX_C_SOURCE explicitly.
10070 dnl
10071 dnl References:
10072 dnl https://pubs.opengroup.org/onlinepubs/007904975/functions/xsh_chap02_02.html
10073 dnl https://docs.oracle.com/cd/E19253-01/816-5175/standards-5/index.html
10074 dnl https://www.gnu.org/software/libc/manual/html_node/Feature-Test-Macros.html
10075 AC_DEFUN([CF_XOPEN_SOURCE],[
10076 AC_REQUIRE([AC_CANONICAL_HOST])
10077 AC_REQUIRE([CF_POSIX_VISIBLE])
10078
10079 if test "$cf_cv_posix_visible" = no; then
10080
10081 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
10082 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
10083 cf_xopen_source=
10084
10085 case "$host_os" in
10086 (aix[[4-7]]*)
10087         cf_xopen_source="-D_ALL_SOURCE"
10088         ;;
10089 (darwin[[0-8]].*)
10090         cf_xopen_source="-D_APPLE_C_SOURCE"
10091         ;;
10092 (darwin*)
10093         cf_xopen_source="-D_DARWIN_C_SOURCE"
10094         cf_XOPEN_SOURCE=
10095         ;;
10096 (freebsd*|dragonfly*|midnightbsd*)
10097         # 5.x headers associate
10098         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
10099         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
10100         cf_POSIX_C_SOURCE=200112L
10101         cf_XOPEN_SOURCE=600
10102         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
10103         ;;
10104 (hpux11*)
10105         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
10106         ;;
10107 (hpux*)
10108         cf_xopen_source="-D_HPUX_SOURCE"
10109         ;;
10110 (irix[[56]].*)
10111         cf_xopen_source="-D_SGI_SOURCE"
10112         cf_XOPEN_SOURCE=
10113         ;;
10114 (linux*gnu|linux*gnuabi64|linux*gnuabin32|linux*gnueabi|linux*gnueabihf|linux*gnux32|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin|msys|mingw*|linux*uclibc)
10115         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
10116         ;;
10117 (minix*)
10118         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
10119         ;;
10120 (mirbsd*)
10121         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
10122         cf_XOPEN_SOURCE=
10123         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
10124         ;;
10125 (netbsd*)
10126         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
10127         ;;
10128 (openbsd[[6-9]]*)
10129         # OpenBSD 6.x has broken locale support, both compile-time and runtime.
10130         # see https://www.mail-archive.com/bugs@openbsd.org/msg13200.html
10131         # Abusing the conformance level is a workaround.
10132         AC_MSG_WARN(this system does not provide usable locale support)
10133         cf_xopen_source="-D_BSD_SOURCE"
10134         cf_XOPEN_SOURCE=700
10135         ;;
10136 (openbsd[[4-5]]*)
10137         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
10138         cf_xopen_source="-D_BSD_SOURCE"
10139         cf_XOPEN_SOURCE=600
10140         ;;
10141 (openbsd*)
10142         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
10143         ;;
10144 (osf[[45]]*)
10145         cf_xopen_source="-D_OSF_SOURCE"
10146         ;;
10147 (nto-qnx*)
10148         cf_xopen_source="-D_QNX_SOURCE"
10149         ;;
10150 (sco*)
10151         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
10152         ;;
10153 (solaris2.*)
10154         cf_xopen_source="-D__EXTENSIONS__"
10155         cf_cv_xopen_source=broken
10156         ;;
10157 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
10158         cf_XOPEN_SOURCE=
10159         cf_POSIX_C_SOURCE=
10160         ;;
10161 (*)
10162         CF_TRY_XOPEN_SOURCE
10163         cf_save_xopen_cppflags="$CPPFLAGS"
10164         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
10165         # Some of these niche implementations use copy/paste, double-check...
10166         if test "$cf_cv_xopen_source" = no ; then
10167                 CF_VERBOSE(checking if _POSIX_C_SOURCE interferes with _XOPEN_SOURCE)
10168                 AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,,[
10169                         AC_MSG_WARN(_POSIX_C_SOURCE definition is not usable)
10170                         CPPFLAGS="$cf_save_xopen_cppflags"])
10171         fi
10172         ;;
10173 esac
10174
10175 if test -n "$cf_xopen_source" ; then
10176         CF_APPEND_CFLAGS($cf_xopen_source,true)
10177 fi
10178
10179 dnl In anything but the default case, we may have system-specific setting
10180 dnl which is still not guaranteed to provide all of the entrypoints that
10181 dnl _XOPEN_SOURCE would yield.
10182 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
10183         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
10184         AC_TRY_COMPILE([#include <stdlib.h>],[
10185 #ifndef _XOPEN_SOURCE
10186 #error _XOPEN_SOURCE is not defined
10187 #endif],
10188         [cf_XOPEN_SOURCE_set=yes],
10189         [cf_XOPEN_SOURCE_set=no])
10190         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
10191         if test "$cf_XOPEN_SOURCE_set" = yes
10192         then
10193                 AC_TRY_COMPILE([#include <stdlib.h>],[
10194 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
10195 #error (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
10196 #endif],
10197                 [cf_XOPEN_SOURCE_set_ok=yes],
10198                 [cf_XOPEN_SOURCE_set_ok=no])
10199                 if test "$cf_XOPEN_SOURCE_set_ok" = no
10200                 then
10201                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
10202                 fi
10203         else
10204                 CF_TRY_XOPEN_SOURCE
10205         fi
10206 fi
10207 fi # cf_cv_posix_visible
10208 ])
10209 dnl ---------------------------------------------------------------------------
10210 dnl CF__SED_TRIMBLANKS version: 1 updated: 2021/01/02 09:31:20
10211 dnl ------------------
10212 dnl Trim something using sed, then trim extra whitespace
10213 dnl $1 = extra parameters, e.g., in CF_STRIP_G_OPT
10214 define([CF__SED_TRIMBLANKS],[sed ifelse($1,,,[$1] )-e 's%[[     ]]% %g' -e 's% [[ ]]*% %g' -e 's%^ %%' -e 's% [$]%%'])dnl
10215 dnl ---------------------------------------------------------------------------
10216 dnl CF__XOPEN_SOURCE_BODY version: 2 updated: 2023/02/18 17:41:25
10217 dnl ---------------------
10218 dnl body of test when test-compiling for _XOPEN_SOURCE check
10219 define([CF__XOPEN_SOURCE_BODY],
10220 [
10221 #ifndef _XOPEN_SOURCE
10222 #error _XOPEN_SOURCE is not defined
10223 #endif
10224 ])
10225 dnl ---------------------------------------------------------------------------
10226 dnl CF__XOPEN_SOURCE_HEAD version: 2 updated: 2023/02/18 17:41:25
10227 dnl ---------------------
10228 dnl headers to include when test-compiling for _XOPEN_SOURCE check
10229 define([CF__XOPEN_SOURCE_HEAD],
10230 [
10231 $ac_includes_default
10232 ])