aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2015,2016 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.800 2016/09/10 19:33:21 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54         [AC_TRY_LINK([#include <langinfo.h>],
  55         [char* cs = nl_langinfo(CODESET);],
  56         am_cv_langinfo_codeset=yes,
  57         am_cv_langinfo_codeset=no)
  58         ])
  59         if test $am_cv_langinfo_codeset = yes; then
  60                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62         fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
  66 dnl ---------------
  67 dnl Provide configure-script defaults for different ncurses ABIs.
  68 AC_DEFUN([CF_ABI_DEFAULTS],[
  69 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  70 case x$cf_cv_abi_version in
  71 (x[[6789]])
  72         cf_dft_ext_colors=yes
  73         cf_dft_ext_const=yes
  74         cf_dft_ext_mouse=yes
  75         cf_dft_ext_putwin=yes
  76         cf_dft_ext_spfuncs=yes
  77         cf_dft_filter_syms=yes
  78         cf_dft_chtype=uint32_t
  79         cf_dft_mmask_t=uint32_t
  80         cf_dft_interop=yes
  81         cf_dft_tparm_arg=intptr_t
  82         cf_dft_with_lp64=yes
  83         ;;
  84 (*)
  85         cf_dft_ext_colors=no
  86         cf_dft_ext_const=no
  87         cf_dft_ext_mouse=no
  88         cf_dft_ext_putwin=no
  89         cf_dft_ext_spfuncs=no
  90         cf_dft_filter_syms=no
  91         cf_dft_chtype=auto
  92         cf_dft_mmask_t=auto
  93         cf_dft_interop=no
  94         cf_dft_tparm_arg=long
  95         cf_dft_with_lp64=no
  96         ;;
  97 esac
  98 ])dnl
  99 dnl ---------------------------------------------------------------------------
 100 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 101 dnl ------------------
 102 dnl Conditionally generate script according to whether we're using a given autoconf.
 103 dnl
 104 dnl $1 = version to compare against
 105 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 106 dnl $3 = code to use if AC_ACVERSION is older than $1.
 107 define([CF_ACVERSION_CHECK],
 108 [
 109 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 110 ifdef([m4_version_compare],
 111 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 112 [CF_ACVERSION_COMPARE(
 113 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 114 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 115 dnl ---------------------------------------------------------------------------
 116 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 117 dnl --------------------
 118 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 119 dnl                      MAJOR2, MINOR2, TERNARY2,
 120 dnl                      PRINTABLE2, not FOUND, FOUND)
 121 define([CF_ACVERSION_COMPARE],
 122 [ifelse(builtin([eval], [$2 < $5]), 1,
 123 [ifelse([$8], , ,[$8])],
 124 [ifelse([$9], , ,[$9])])])dnl
 125 dnl ---------------------------------------------------------------------------
 126 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 127 dnl -------------------
 128 dnl Construct the list of include-options for the C programs in the Ada95
 129 dnl binding.
 130 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 131 [
 132 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 133 if test "$srcdir" != "."; then
 134         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 135 fi
 136 if test "$GCC" != yes; then
 137         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 138 elif test "$includedir" != "/usr/include"; then
 139         if test "$includedir" = '${prefix}/include' ; then
 140                 if test x$prefix != x/usr ; then
 141                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 142                 fi
 143         else
 144                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 145         fi
 146 fi
 147 AC_SUBST(ACPPFLAGS)
 148 ])dnl
 149 dnl ---------------------------------------------------------------------------
 150 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 151 dnl ---------------
 152 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 153 AC_DEFUN([CF_ADD_ADAFLAGS],[
 154         ADAFLAGS="$ADAFLAGS $1"
 155         AC_SUBST(ADAFLAGS)
 156 ])dnl
 157 dnl ---------------------------------------------------------------------------
 158 dnl CF_ADD_CFLAGS version: 12 updated: 2015/04/12 15:39:00
 159 dnl -------------
 160 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 161 dnl The second parameter if given makes this macro verbose.
 162 dnl
 163 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 164 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 165 dnl confused by the quotes (which require backslashes to keep them usable).
 166 AC_DEFUN([CF_ADD_CFLAGS],
 167 [
 168 cf_fix_cppflags=no
 169 cf_new_cflags=
 170 cf_new_cppflags=
 171 cf_new_extra_cppflags=
 172
 173 for cf_add_cflags in $1
 174 do
 175 case $cf_fix_cppflags in
 176 (no)
 177         case $cf_add_cflags in
 178         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 179                 case $cf_add_cflags in
 180                 (-D*)
 181                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 182
 183                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 184                                 && test -z "${cf_tst_cflags}" \
 185                                 && cf_fix_cppflags=yes
 186
 187                         if test $cf_fix_cppflags = yes ; then
 188                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 189                                 continue
 190                         elif test "${cf_tst_cflags}" = "\"'" ; then
 191                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 192                                 continue
 193                         fi
 194                         ;;
 195                 esac
 196                 case "$CPPFLAGS" in
 197                 (*$cf_add_cflags)
 198                         ;;
 199                 (*)
 200                         case $cf_add_cflags in
 201                         (-D*)
 202                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 203                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 204                                 ;;
 205                         esac
 206                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 207                         ;;
 208                 esac
 209                 ;;
 210         (*)
 211                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 212                 ;;
 213         esac
 214         ;;
 215 (yes)
 216         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 217
 218         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 219
 220         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 221                 && test -z "${cf_tst_cflags}" \
 222                 && cf_fix_cppflags=no
 223         ;;
 224 esac
 225 done
 226
 227 if test -n "$cf_new_cflags" ; then
 228         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 229         CFLAGS="$CFLAGS $cf_new_cflags"
 230 fi
 231
 232 if test -n "$cf_new_cppflags" ; then
 233         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 234         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 235 fi
 236
 237 if test -n "$cf_new_extra_cppflags" ; then
 238         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 239         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 240 fi
 241
 242 AC_SUBST(EXTRA_CPPFLAGS)
 243
 244 ])dnl
 245 dnl ---------------------------------------------------------------------------
 246 dnl CF_ADD_INCDIR version: 14 updated: 2015/05/25 20:53:04
 247 dnl -------------
 248 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 249 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 250 dnl but old versions (and some misinstalled ones) need that.  To make things
 251 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 252 dnl the include-path).
 253 AC_DEFUN([CF_ADD_INCDIR],
 254 [
 255 if test -n "$1" ; then
 256   for cf_add_incdir in $1
 257   do
 258         while test $cf_add_incdir != /usr/include
 259         do
 260           if test -d $cf_add_incdir
 261           then
 262                 cf_have_incdir=no
 263                 if test -n "$CFLAGS$CPPFLAGS" ; then
 264                   # a loop is needed to ensure we can add subdirs of existing dirs
 265                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 266                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 267                           cf_have_incdir=yes; break
 268                         fi
 269                   done
 270                 fi
 271
 272                 if test "$cf_have_incdir" = no ; then
 273                   if test "$cf_add_incdir" = /usr/local/include ; then
 274                         if test "$GCC" = yes
 275                         then
 276                           cf_save_CPPFLAGS=$CPPFLAGS
 277                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 278                           AC_TRY_COMPILE([#include <stdio.h>],
 279                                   [printf("Hello")],
 280                                   [],
 281                                   [cf_have_incdir=yes])
 282                           CPPFLAGS=$cf_save_CPPFLAGS
 283                         fi
 284                   fi
 285                 fi
 286
 287                 if test "$cf_have_incdir" = no ; then
 288                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 289                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 290
 291                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 292                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 293                   cf_add_incdir="$cf_top_incdir"
 294                 else
 295                   break
 296                 fi
 297           else
 298                 break
 299           fi
 300         done
 301   done
 302 fi
 303 ])dnl
 304 dnl ---------------------------------------------------------------------------
 305 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 306 dnl ----------
 307 dnl Add a library, used to enforce consistency.
 308 dnl
 309 dnl $1 = library to add, without the "-l"
 310 dnl $2 = variable to update (default $LIBS)
 311 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 312 dnl ---------------------------------------------------------------------------
 313 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 314 dnl -------------
 315 dnl     Adds to the library-path
 316 dnl
 317 dnl     Some machines have trouble with multiple -L options.
 318 dnl
 319 dnl $1 is the (list of) directory(s) to add
 320 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 321 dnl
 322 AC_DEFUN([CF_ADD_LIBDIR],
 323 [
 324 if test -n "$1" ; then
 325         for cf_add_libdir in $1
 326         do
 327                 if test $cf_add_libdir = /usr/lib ; then
 328                         :
 329                 elif test -d $cf_add_libdir
 330                 then
 331                         cf_have_libdir=no
 332                         if test -n "$LDFLAGS$LIBS" ; then
 333                                 # a loop is needed to ensure we can add subdirs of existing dirs
 334                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 335                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 336                                                 cf_have_libdir=yes; break
 337                                         fi
 338                                 done
 339                         fi
 340                         if test "$cf_have_libdir" = no ; then
 341                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 342                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 343                         fi
 344                 fi
 345         done
 346 fi
 347 ])dnl
 348 dnl ---------------------------------------------------------------------------
 349 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 350 dnl -----------
 351 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 352 dnl prepended to an existing list, since their dependencies are assumed to
 353 dnl already exist in the list.
 354 dnl
 355 dnl $1 = libraries to add, with the "-l", etc.
 356 dnl $2 = variable to update (default $LIBS)
 357 AC_DEFUN([CF_ADD_LIBS],[
 358 cf_add_libs="$1"
 359 # Filter out duplicates - this happens with badly-designed ".pc" files...
 360 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 361 do
 362         for cf_add_2lib in $cf_add_libs
 363         do
 364                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 365                 then
 366                         cf_add_1lib=
 367                         break
 368                 fi
 369         done
 370         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 371 done
 372 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 373 ])dnl
 374 dnl ---------------------------------------------------------------------------
 375 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 376 dnl ------------------
 377 dnl Append to a search-list for a nonstandard header/lib-file
 378 dnl     $1 = the variable to return as result
 379 dnl     $2 = the package name
 380 dnl     $3 = the subdirectory, e.g., bin, include or lib
 381 dnl $4 = the directory under which we will test for subdirectories
 382 dnl $5 = a directory that we do not want $4 to match
 383 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 384 [
 385 test "x$4" != "x$5" && \
 386 test -d "$4" && \
 387 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 388         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 389         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 390         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 391         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 392         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 393         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 394 }
 395 ])dnl
 396 dnl ---------------------------------------------------------------------------
 397 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 398 dnl --------------
 399 dnl Allow user to disable a normally-on option.
 400 AC_DEFUN([CF_ARG_DISABLE],
 401 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 402 dnl ---------------------------------------------------------------------------
 403 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 404 dnl -------------
 405 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 406 dnl values.
 407 dnl
 408 dnl Parameters:
 409 dnl $1 = option name
 410 dnl $2 = help-string
 411 dnl $3 = action to perform if option is not default
 412 dnl $4 = action if perform if option is default
 413 dnl $5 = default option value (either 'yes' or 'no')
 414 AC_DEFUN([CF_ARG_OPTION],
 415 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 416         if test "$enableval" != "$5" ; then
 417 ifelse([$3],,[    :]dnl
 418 ,[    $3]) ifelse([$4],,,[
 419         else
 420                 $4])
 421         fi],[enableval=$5 ifelse([$4],,,[
 422         $4
 423 ])dnl
 424 ])])dnl
 425 dnl ---------------------------------------------------------------------------
 426 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
 427 dnl -----------
 428 dnl Check for suitable "ar" (archiver) options for updating an archive.
 429 dnl
 430 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 431 dnl as well as a workaround for breakage of make's archive rules by the GNU
 432 dnl binutils "ar" program.
 433 AC_DEFUN([CF_AR_FLAGS],[
 434 AC_REQUIRE([CF_PROG_AR])
 435
 436 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 437         cf_cv_ar_flags=unknown
 438         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 439         do
 440
 441                 # check if $ARFLAGS already contains this choice
 442                 if test "x$ARFLAGS" != "x" ; then
 443                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 444                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 445                                 cf_cv_ar_flags=
 446                                 break
 447                         fi
 448                 fi
 449
 450                 rm -f conftest.$ac_cv_objext
 451                 rm -f conftest.a
 452
 453                 cat >conftest.$ac_ext <<EOF
 454 #line __oline__ "configure"
 455 int     testdata[[3]] = { 123, 456, 789 };
 456 EOF
 457                 if AC_TRY_EVAL(ac_compile) ; then
 458                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 459                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 460                         if test -f conftest.a ; then
 461                                 cf_cv_ar_flags=$cf_ar_flags
 462                                 break
 463                         fi
 464                 else
 465                         CF_VERBOSE(cannot compile test-program)
 466                         break
 467                 fi
 468         done
 469         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 470 ])
 471
 472 if test -n "$ARFLAGS" ; then
 473         if test -n "$cf_cv_ar_flags" ; then
 474                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 475         fi
 476 else
 477         ARFLAGS=$cf_cv_ar_flags
 478 fi
 479
 480 AC_SUBST(ARFLAGS)
 481 ])
 482 dnl ---------------------------------------------------------------------------
 483 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 484 dnl -----------------
 485 dnl Check if awk can handle big strings using printf.  Some older versions of
 486 dnl awk choke on large strings passed via "%s".
 487 dnl
 488 dnl $1 = desired string size
 489 dnl $2 = variable to set with result
 490 AC_DEFUN([CF_AWK_BIG_PRINTF],
 491 [
 492         case x$AWK in
 493         (x)
 494                 eval $2=no
 495                 ;;
 496         (*)
 497                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 498                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 499                         eval $2=yes
 500                 else
 501                         eval $2=no
 502                 fi
 503                 ;;
 504         esac
 505 ])dnl
 506 dnl ---------------------------------------------------------------------------
 507 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 508 dnl ------------
 509 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 510 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 511 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 512 dnl
 513 dnl Treat the configuration-variable specially here, since we're directly
 514 dnl substituting its value (i.e., 1/0).
 515 dnl
 516 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 517 AC_DEFUN([CF_BOOL_DECL],
 518 [
 519 AC_MSG_CHECKING(if we should include stdbool.h)
 520
 521 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 522         AC_TRY_COMPILE([],[bool foo = false],
 523                 [cf_cv_header_stdbool_h=0],
 524                 [AC_TRY_COMPILE([
 525 #ifndef __BEOS__
 526 #include <stdbool.h>
 527 #endif
 528 ],[bool foo = false],
 529                         [cf_cv_header_stdbool_h=1],
 530                         [cf_cv_header_stdbool_h=0])])])
 531
 532 if test "$cf_cv_header_stdbool_h" = 1
 533 then    AC_MSG_RESULT(yes)
 534 else    AC_MSG_RESULT(no)
 535 fi
 536
 537 AC_MSG_CHECKING([for builtin bool type])
 538
 539 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 540         AC_TRY_COMPILE([
 541 #include <stdio.h>
 542 #include <sys/types.h>
 543 ],[bool x = false],
 544                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 545                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 546         ])
 547
 548 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 549 then    AC_MSG_RESULT(yes)
 550 else    AC_MSG_RESULT(no)
 551 fi
 552 ])dnl
 553 dnl ---------------------------------------------------------------------------
 554 dnl CF_BOOL_SIZE version: 14 updated: 2015/04/17 21:13:04
 555 dnl ------------
 556 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 557 dnl Don't bother looking for bool.h, since it's been deprecated.
 558 dnl
 559 dnl If the current compiler is C rather than C++, we get the bool definition
 560 dnl from <stdbool.h>.
 561 AC_DEFUN([CF_BOOL_SIZE],
 562 [
 563 AC_MSG_CHECKING([for size of bool])
 564 AC_CACHE_VAL(cf_cv_type_of_bool,[
 565         rm -f cf_test.out
 566         AC_TRY_RUN([
 567 #include <stdlib.h>
 568 #include <stdio.h>
 569
 570 #if defined(__cplusplus)
 571
 572 #ifdef HAVE_GXX_BUILTIN_H
 573 #include <g++/builtin.h>
 574 #elif HAVE_GPP_BUILTIN_H
 575 #include <gpp/builtin.h>
 576 #elif HAVE_BUILTIN_H
 577 #include <builtin.h>
 578 #endif
 579
 580 #else
 581
 582 #if $cf_cv_header_stdbool_h
 583 #include <stdbool.h>
 584 #endif
 585
 586 #endif
 587
 588 int main()
 589 {
 590         FILE *fp = fopen("cf_test.out", "w");
 591         if (fp != 0) {
 592                 bool x = true;
 593                 if ((bool)(-x) >= 0)
 594                         fputs("unsigned ", fp);
 595                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 596                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 597                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 598                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 599                 fclose(fp);
 600         }
 601         ${cf_cv_main_return:-return}(0);
 602 }
 603                 ],
 604                 [cf_cv_type_of_bool=`cat cf_test.out`
 605                  if test -z "$cf_cv_type_of_bool"; then
 606                    cf_cv_type_of_bool=unknown
 607                  fi],
 608                 [cf_cv_type_of_bool=unknown],
 609                 [cf_cv_type_of_bool=unknown])
 610         ])
 611         rm -f cf_test.out
 612 AC_MSG_RESULT($cf_cv_type_of_bool)
 613 if test "$cf_cv_type_of_bool" = unknown ; then
 614         case .$NCURSES_BOOL in
 615         (.auto|.) NCURSES_BOOL=unsigned;;
 616         esac
 617         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 618         cf_cv_type_of_bool=$NCURSES_BOOL
 619 fi
 620 ])dnl
 621 dnl ---------------------------------------------------------------------------
 622 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 623 dnl -----------
 624 dnl If we're cross-compiling, allow the user to override the tools and their
 625 dnl options.  The configure script is oriented toward identifying the host
 626 dnl compiler, etc., but we need a build compiler to generate parts of the
 627 dnl source.
 628 dnl
 629 dnl $1 = default for $CPPFLAGS
 630 dnl $2 = default for $LIBS
 631 AC_DEFUN([CF_BUILD_CC],[
 632 CF_ACVERSION_CHECK(2.52,,
 633         [AC_REQUIRE([CF_PROG_EXT])])
 634 if test "$cross_compiling" = yes ; then
 635
 636         # defaults that we might want to override
 637         : ${BUILD_CFLAGS:=''}
 638         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 639         : ${BUILD_LDFLAGS:=''}
 640         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 641         : ${BUILD_EXEEXT:='$x'}
 642         : ${BUILD_OBJEXT:='o'}
 643
 644         AC_ARG_WITH(build-cc,
 645                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 646                 [BUILD_CC="$withval"],
 647                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 648         AC_MSG_CHECKING(for native build C compiler)
 649         AC_MSG_RESULT($BUILD_CC)
 650
 651         AC_MSG_CHECKING(for native build C preprocessor)
 652         AC_ARG_WITH(build-cpp,
 653                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 654                 [BUILD_CPP="$withval"],
 655                 [BUILD_CPP='${BUILD_CC} -E'])
 656         AC_MSG_RESULT($BUILD_CPP)
 657
 658         AC_MSG_CHECKING(for native build C flags)
 659         AC_ARG_WITH(build-cflags,
 660                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 661                 [BUILD_CFLAGS="$withval"])
 662         AC_MSG_RESULT($BUILD_CFLAGS)
 663
 664         AC_MSG_CHECKING(for native build C preprocessor-flags)
 665         AC_ARG_WITH(build-cppflags,
 666                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 667                 [BUILD_CPPFLAGS="$withval"])
 668         AC_MSG_RESULT($BUILD_CPPFLAGS)
 669
 670         AC_MSG_CHECKING(for native build linker-flags)
 671         AC_ARG_WITH(build-ldflags,
 672                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 673                 [BUILD_LDFLAGS="$withval"])
 674         AC_MSG_RESULT($BUILD_LDFLAGS)
 675
 676         AC_MSG_CHECKING(for native build linker-libraries)
 677         AC_ARG_WITH(build-libs,
 678                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 679                 [BUILD_LIBS="$withval"])
 680         AC_MSG_RESULT($BUILD_LIBS)
 681
 682         # this assumes we're on Unix.
 683         BUILD_EXEEXT=
 684         BUILD_OBJEXT=o
 685
 686         : ${BUILD_CC:='${CC}'}
 687
 688         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 689                 AC_MSG_ERROR([Cross-build requires two compilers.
 690 Use --with-build-cc to specify the native compiler.])
 691         fi
 692
 693 else
 694         : ${BUILD_CC:='${CC}'}
 695         : ${BUILD_CPP:='${CPP}'}
 696         : ${BUILD_CFLAGS:='${CFLAGS}'}
 697         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 698         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 699         : ${BUILD_LIBS:='${LIBS}'}
 700         : ${BUILD_EXEEXT:='$x'}
 701         : ${BUILD_OBJEXT:='o'}
 702 fi
 703
 704 AC_SUBST(BUILD_CC)
 705 AC_SUBST(BUILD_CPP)
 706 AC_SUBST(BUILD_CFLAGS)
 707 AC_SUBST(BUILD_CPPFLAGS)
 708 AC_SUBST(BUILD_LDFLAGS)
 709 AC_SUBST(BUILD_LIBS)
 710 AC_SUBST(BUILD_EXEEXT)
 711 AC_SUBST(BUILD_OBJEXT)
 712 ])dnl
 713 dnl ---------------------------------------------------------------------------
 714 dnl CF_CC_ENV_FLAGS version: 6 updated: 2016/08/29 20:57:00
 715 dnl ---------------
 716 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 717 dnl into CC.  This will not help with broken scripts that wrap the compiler
 718 dnl with options, but eliminates a more common category of user confusion.
 719 dnl
 720 dnl In particular, it addresses the problem of being able to run the C
 721 dnl preprocessor in a consistent manner.
 722 dnl
 723 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 724 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 725 dnl outweighs that limitation.
 726 AC_DEFUN([CF_CC_ENV_FLAGS],
 727 [
 728 # This should have been defined by AC_PROG_CC
 729 : ${CC:=cc}
 730
 731 AC_MSG_CHECKING(\$CC variable)
 732 case "$CC" in
 733 (*[[\ \ ]]-*)
 734         AC_MSG_RESULT(broken)
 735         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 736         # humor him...
 737         cf_flags=`echo "$CC" | sed -e 's/^.*[[  ]]\(-[[^        ]]\)/\1/'`
 738         CC=`echo "$CC " | sed -e 's/[[  ]]-[[^  ]].*$//' -e 's/[[       ]]*$//'`
 739         for cf_arg in $cf_flags
 740         do
 741                 case "x$cf_arg" in
 742                 (x-[[IUDfgOW]]*)
 743                         CF_ADD_CFLAGS($cf_flags)
 744                         ;;
 745                 (*)
 746                         CC="$CC $cf_arg"
 747                         ;;
 748                 esac
 749         done
 750         CF_VERBOSE(resulting CC: '$CC')
 751         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 752         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 753         ;;
 754 (*)
 755         AC_MSG_RESULT(ok)
 756         ;;
 757 esac
 758 ])dnl
 759 dnl ---------------------------------------------------------------------------
 760 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 761 dnl ---------------
 762 dnl Determine the default configuration into which we'll install ncurses.  This
 763 dnl can be overridden by the user's command-line options.  There's two items to
 764 dnl look for:
 765 dnl     1. the prefix (e.g., /usr)
 766 dnl     2. the header files (e.g., /usr/include/ncurses)
 767 dnl We'll look for a previous installation of ncurses and use the same defaults.
 768 dnl
 769 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 770 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 771 dnl programs from a vendor's.
 772 AC_DEFUN([CF_CFG_DEFAULTS],
 773 [
 774 AC_MSG_CHECKING(for prefix)
 775 if test "x$prefix" = "xNONE" ; then
 776         case "$cf_cv_system_name" in
 777                 # non-vendor systems don't have a conflict
 778         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 779                 prefix=/usr
 780                 ;;
 781         (*)     prefix=$ac_default_prefix
 782                 ;;
 783         esac
 784 fi
 785 AC_MSG_RESULT($prefix)
 786
 787 if test "x$prefix" = "xNONE" ; then
 788 AC_MSG_CHECKING(for default include-directory)
 789 test -n "$verbose" && echo 1>&AC_FD_MSG
 790 for cf_symbol in \
 791         $includedir \
 792         $includedir/ncurses \
 793         $prefix/include \
 794         $prefix/include/ncurses \
 795         /usr/local/include \
 796         /usr/local/include/ncurses \
 797         /usr/include \
 798         /usr/include/ncurses
 799 do
 800         cf_dir=`eval echo $cf_symbol`
 801         if test -f $cf_dir/curses.h ; then
 802         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 803                 includedir="$cf_symbol"
 804                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 805                 break
 806         fi
 807         fi
 808         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 809 done
 810 AC_MSG_RESULT($includedir)
 811 fi
 812 ])dnl
 813 dnl ---------------------------------------------------------------------------
 814 dnl CF_CGETENT version: 5 updated: 2012/10/06 17:56:13
 815 dnl ----------
 816 dnl Check if the terminal-capability database functions are available.  If not,
 817 dnl ncurses has a much-reduced version.
 818 AC_DEFUN([CF_CGETENT],[
 819 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 820 AC_TRY_LINK([
 821 #include <stdlib.h>],[
 822         char temp[128];
 823         char *buf = temp;
 824         char *db_array = temp;
 825         cgetent(&buf, &db_array, "vt100");
 826         cgetcap(buf, "tc", '=');
 827         cgetmatch(buf, "tc");
 828         ],
 829         [cf_cv_cgetent=yes],
 830         [cf_cv_cgetent=no])
 831 ])
 832
 833 if test "$cf_cv_cgetent" = yes
 834 then
 835         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 836 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 837 AC_TRY_LINK([
 838 #include <stdlib.h>],[
 839         char temp[128];
 840         char *buf = temp;
 841 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 842         const char *db_array = temp;
 843         cgetent(&buf, &db_array, "vt100");
 844 #endif
 845         cgetcap(buf, "tc", '=');
 846         cgetmatch(buf, "tc");
 847         ],
 848         [cf_cv_cgetent_const=yes],
 849         [cf_cv_cgetent_const=no])
 850 ])
 851         if test "$cf_cv_cgetent_const" = yes
 852         then
 853                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 854         fi
 855 fi
 856 ])dnl
 857 dnl ---------------------------------------------------------------------------
 858 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 859 dnl --------------
 860 dnl Check if we're accidentally using a cache from a different machine.
 861 dnl Derive the system name, as a check for reusing the autoconf cache.
 862 dnl
 863 dnl If we've packaged config.guess and config.sub, run that (since it does a
 864 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 865 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 866 dnl which is useful in cross-compiles.
 867 dnl
 868 dnl Note: we would use $ac_config_sub, but that is one of the places where
 869 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 870 AC_DEFUN([CF_CHECK_CACHE],
 871 [
 872 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 873         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 874         system_name="$host_os"
 875 else
 876         system_name="`(uname -s -r) 2>/dev/null`"
 877         if test -z "$system_name" ; then
 878                 system_name="`(hostname) 2>/dev/null`"
 879         fi
 880 fi
 881 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 882 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 883
 884 test -z "$system_name" && system_name="$cf_cv_system_name"
 885 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 886
 887 if test ".$system_name" != ".$cf_cv_system_name" ; then
 888         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 889         AC_MSG_ERROR("Please remove config.cache and try again.")
 890 fi
 891 ])dnl
 892 dnl ---------------------------------------------------------------------------
 893 dnl CF_CHECK_ERRNO version: 12 updated: 2015/04/18 08:56:57
 894 dnl --------------
 895 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 896 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 897 dnl ourselves.
 898 dnl
 899 dnl $1 = the name to check
 900 dnl $2 = the assumed type
 901 AC_DEFUN([CF_CHECK_ERRNO],
 902 [
 903 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 904         AC_TRY_COMPILE([
 905 #ifdef HAVE_STDLIB_H
 906 #include <stdlib.h>
 907 #endif
 908 #include <stdio.h>
 909 #include <sys/types.h>
 910 #include <errno.h> ],
 911         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 912         [cf_cv_dcl_$1=yes],
 913         [cf_cv_dcl_$1=no])
 914 ])
 915
 916 if test "$cf_cv_dcl_$1" = no ; then
 917         CF_UPPER(cf_result,decl_$1)
 918         AC_DEFINE_UNQUOTED($cf_result)
 919 fi
 920
 921 # It's possible (for near-UNIX clones) that the data doesn't exist
 922 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 923 ])dnl
 924 dnl ---------------------------------------------------------------------------
 925 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
 926 dnl --------------------
 927 dnl Check for existence of external data in the current set of libraries.  If
 928 dnl we can modify it, it's real enough.
 929 dnl $1 = the name to check
 930 dnl $2 = its type
 931 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 932 [
 933 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 934         AC_TRY_LINK([
 935 #undef $1
 936 extern $2 $1;
 937 ],
 938         [$1 = 2],
 939         [cf_cv_have_$1=yes],
 940         [cf_cv_have_$1=no])
 941 ])
 942
 943 if test "$cf_cv_have_$1" = yes ; then
 944         CF_UPPER(cf_result,have_$1)
 945         AC_DEFINE_UNQUOTED($cf_result)
 946 fi
 947
 948 ])dnl
 949 dnl ---------------------------------------------------------------------------
 950 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 951 dnl -------------------
 952 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 953 dnl is not "weak" - warn about this because it can create problems linking
 954 dnl applications with ncurses.
 955 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 956 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 957
 958 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 959 cf_cv_check_gpm_wgetch=unknown
 960 if test "$cross_compiling" != yes ; then
 961
 962 cat >conftest.$ac_ext <<CF_EOF
 963 #include <gpm.h>
 964 int main()
 965 {
 966         Gpm_Wgetch();
 967         ${cf_cv_main_return:-return}(0);
 968 }
 969 CF_EOF
 970
 971         cf_save_LIBS="$LIBS"
 972         # This only works if we can look at the symbol table.  If a shared
 973         # library is stripped for install, we cannot use that.  So we're forced
 974         # to rely on the static library, noting that some packagers may not
 975         # include it.
 976         LIBS="-static -lgpm -dynamic $LIBS"
 977         if AC_TRY_EVAL(ac_compile) ; then
 978                 if AC_TRY_EVAL(ac_link) ; then
 979                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 980                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 981                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 982                 fi
 983         fi
 984         rm -rf conftest*
 985         LIBS="$cf_save_LIBS"
 986 fi
 987 ])
 988
 989 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 990         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 991 fi
 992 ])])dnl
 993 dnl ---------------------------------------------------------------------------
 994 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
 995 dnl ------------------------
 996 dnl Show the version of libtool
 997 dnl
 998 dnl Save the version in a cache variable - this is not entirely a good thing,
 999 dnl but the version string from libtool is very ugly, and for bug reports it
1000 dnl might be useful to have the original string.
1001 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1002 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1003 then
1004         AC_MSG_CHECKING(version of $LIBTOOL)
1005         CF_LIBTOOL_VERSION
1006         AC_MSG_RESULT($cf_cv_libtool_version)
1007         if test -z "$cf_cv_libtool_version" ; then
1008                 AC_MSG_ERROR(This is not GNU libtool)
1009         fi
1010 else
1011         AC_MSG_ERROR(GNU libtool has not been found)
1012 fi
1013 ])dnl
1014 dnl ---------------------------------------------------------------------------
1015 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
1016 dnl ----------------
1017 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1018 AC_DEFUN([CF_CHECK_WCHAR_H],[
1019 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1020 AC_TRY_COMPILE(
1021 [
1022 #include <stdlib.h>
1023 #include <wchar.h>
1024 ],[
1025         wint_t foo = 0;
1026         int bar = iswpunct(foo)],
1027         [cf_cv_wchar_h_okay=yes],
1028         [cf_cv_wchar_h_okay=no])])
1029
1030 if test $cf_cv_wchar_h_okay = no
1031 then
1032         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1033 fi
1034 ])dnl
1035 dnl ---------------------------------------------------------------------------
1036 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 1 updated: 2015/12/19 17:47:56
1037 dnl -------------------------
1038 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1039 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1040 dnl
1041 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1042 dnl all of those were combined into a page of useful graphics characters.
1043 dnl
1044 dnl So far, so good.
1045 dnl
1046 dnl However, while they are useful, there are other considerations.  CJK
1047 dnl is (because of poor device resolution) often rendered as double-width
1048 dnl characters.  So... for these generally-useful characters, what should
1049 dnl be the width (to make them consistent with adjacent characters)?
1050 dnl
1051 dnl The obvious choice would have been to make this locale-dependent, and use
1052 dnl wcwidth() to tell applications what the actual width is.  That was too
1053 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1054 dnl See for example
1055 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1056 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1057 dnl
1058 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1059 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1060 dnl instance, it lists half (44/96) of the Latin-1 characters as
1061 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1062 dnl
1063 dnl What this means for the implementor is that on some systems wcwidth() can
1064 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1065 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1066 dnl characters).  These do not necessarily match the behavior of the terminal
1067 dnl emulator.  xterm, for instance, does an optional startup check to find if
1068 dnl this problem (or similar) exists with the system's locale tables, rejecting
1069 dnl them if they are too unreliable.
1070 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1071 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1072 cat >conftest.in <<CF_EOF
1073 -       VT100 symbols
1074 0x250c  upper left corner
1075 0x2514  lower left corner
1076 0x2510  upper right corner
1077 0x2518  lower right corner
1078 0x251c  tee pointing left
1079 0x2524  tee pointing right
1080 0x2534  tee pointing up
1081 0x252c  tee pointing down
1082 0x2500  horizontal line
1083 0x2502  vertical line
1084 0x253c  large plus or crossover
1085 0x23ba  scan line 1
1086 0x23bd  scan line 9
1087 0x25c6  diamond
1088 0x2592  checker board (stipple)
1089 0x00b0  degree symbol
1090 0x00b1  plus/minus
1091 0x00b7  bullet
1092 -       Teletype 5410v1 symbols
1093 0x2190  arrow pointing left
1094 0x2192  arrow pointing right
1095 0x2193  arrow pointing down
1096 0x2191  arrow pointing up
1097 0x2592  board of squares
1098 0x2603  lantern symbol
1099 0x25ae  solid square block
1100 -       these defaults were invented for ncurses
1101 0x23bb  scan line 3
1102 0x23bc  scan line 7
1103 0x2264  less-than-or-equal-to
1104 0x2265  greater-than-or-equal-to
1105 0x03c0  greek pi
1106 0x2260  not-equal
1107 0x00a3  pound-sterling symbol
1108 -       thick-line-drawing
1109 0x250f  upper left corner
1110 0x2517  lower left corner
1111 0x2513  upper right corner
1112 0x251b  lower right corner
1113 0x2523  tee pointing left
1114 0x252b  tee pointing right
1115 0x253b  tee pointing up
1116 0x2533  tee pointing down
1117 0x2501  horizontal line
1118 0x2503  vertical line
1119 0x254b  large plus or crossover
1120 -       double-line-drawing
1121 0x2554  upper left corner
1122 0x255a  lower left corner
1123 0x2557  upper right corner
1124 0x255d  lower right corner
1125 0x2563  tee pointing left
1126 0x2560  tee pointing right
1127 0x2569  tee pointing up
1128 0x2566  tee pointing down
1129 0x2550  horizontal line
1130 0x2551  vertical line
1131 0x256c  large plus or crossover
1132 CF_EOF
1133 AC_TRY_RUN([
1134 #include <locale.h>
1135 #include <stdio.h>
1136 #include <wchar.h>
1137
1138 #define MY_LEN 80
1139
1140 int
1141 main(void)
1142 {
1143         FILE *fp;
1144         int value;
1145         char buffer[MY_LEN + 1];
1146         char notes[MY_LEN + 1];
1147         int totals = 0;
1148         int passed = 0;
1149
1150         if (setlocale(LC_ALL, "en_US.UTF8") ||
1151                 setlocale(LC_ALL, "en_US.UTF-8") ||
1152                 setlocale(LC_ALL, "en_US.utf8") ||
1153                 setlocale(LC_ALL, "en_US.utf-8")) {
1154                 if ((fp = fopen("conftest.in", "r")) != 0) {
1155                         while (fgets(buffer, MY_LEN, fp) != 0) {
1156                                 if (*buffer == '-') {
1157                                         fprintf(stderr, "\t%s", buffer);
1158                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1159                                         ++totals;
1160                                         if (wcwidth(value) == 1)
1161                                                 ++passed;
1162                                         fprintf(stderr, "%d\t%s", wcwidth(value), buffer);
1163                                 } else {
1164                                         fprintf(stderr, "?\t%s", buffer);
1165                                 }
1166                         }
1167                 }
1168         }
1169         fprintf(stderr, "%d/%d passed wcwidth/graphics check\n", passed, totals);
1170         return (totals == passed) ? 0 : 1;
1171 }
1172 ],
1173 [cf_cv_wcwidth_graphics=yes],
1174 [cf_cv_wcwidth_graphics=no],
1175 [cf_cv_wcwidth_graphics=unknown])
1176 ])
1177 ])dnl
1178 dnl ---------------------------------------------------------------------------
1179 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
1180 dnl -----------------
1181 dnl Check if the given compiler is really clang.  clang's C driver defines
1182 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1183 dnl not ignore some gcc options.
1184 dnl
1185 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1186 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1187 dnl the wrappers for gcc and g++ warnings.
1188 dnl
1189 dnl $1 = GCC (default) or GXX
1190 dnl $2 = CLANG_COMPILER (default)
1191 dnl $3 = CFLAGS (default) or CXXFLAGS
1192 AC_DEFUN([CF_CLANG_COMPILER],[
1193 ifelse([$2],,CLANG_COMPILER,[$2])=no
1194
1195 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1196         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1197         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1198         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
1199         AC_TRY_COMPILE([],[
1200 #ifdef __clang__
1201 #else
1202 make an error
1203 #endif
1204 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1205 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1206 ],[])
1207         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1208         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1209 fi
1210 ])
1211 dnl ---------------------------------------------------------------------------
1212 dnl CF_CPP_PARAM_INIT version: 6 updated: 2012/10/06 17:56:13
1213 dnl -----------------
1214 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1215 dnl is a late feature for the standard and is not in some recent compilers
1216 dnl (1999/9/11).
1217 AC_DEFUN([CF_CPP_PARAM_INIT],
1218 [
1219 if test -n "$CXX"; then
1220 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1221         AC_LANG_SAVE
1222         AC_LANG_CPLUSPLUS
1223         AC_TRY_RUN([
1224 class TEST {
1225 private:
1226         int value;
1227 public:
1228         TEST(int x = 1);
1229         ~TEST();
1230 };
1231
1232 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1233 {
1234         value = x;
1235 }
1236 int main() { }
1237 ],
1238         [cf_cv_cpp_param_init=yes],
1239         [cf_cv_cpp_param_init=no],
1240         [cf_cv_cpp_param_init=unknown])
1241         AC_LANG_RESTORE
1242 ])
1243 fi
1244 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1245 ])dnl
1246 dnl ---------------------------------------------------------------------------
1247 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1248 dnl ------------------
1249 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1250 dnl not be supported in g++ before 3.0
1251 AC_DEFUN([CF_CPP_STATIC_CAST],
1252 [
1253 if test -n "$CXX"; then
1254
1255 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1256         AC_LANG_SAVE
1257         AC_LANG_CPLUSPLUS
1258
1259         AC_TRY_COMPILE([
1260 class NCursesPanel
1261 {
1262 public:
1263   NCursesPanel(int nlines,
1264                int ncols,
1265                int begin_y = 0,
1266                int begin_x = 0)
1267   {
1268   }
1269   NCursesPanel();
1270   ~NCursesPanel();
1271 };
1272
1273 template<class T> class NCursesUserPanel : public NCursesPanel
1274 {
1275 public:
1276   NCursesUserPanel (int nlines,
1277                     int ncols,
1278                     int begin_y = 0,
1279                     int begin_x = 0,
1280                     const T* p_UserData = static_cast<T*>(0))
1281     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1282   {
1283   };
1284   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1285   {
1286   };
1287
1288   virtual ~NCursesUserPanel() {};
1289 };
1290 ],[
1291         const char* p_UserData = static_cast<char*>(0)],
1292         [cf_cv_cpp_static_cast=yes],
1293         [cf_cv_cpp_static_cast=no])
1294
1295         AC_LANG_RESTORE
1296 ])
1297
1298 fi
1299
1300 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1301 ])dnl
1302 dnl ---------------------------------------------------------------------------
1303 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1304 dnl ---------------
1305 dnl Setup special archiver flags for given compilers.
1306 AC_DEFUN([CF_CXX_AR_FLAGS],[
1307         CXX_AR='$(AR)'
1308         CXX_ARFLAGS='$(ARFLAGS)'
1309         case $cf_cv_system_name in
1310         (irix*)
1311             if test "$GXX" != yes ; then
1312                 CXX_AR='$(CXX)'
1313                 CXX_ARFLAGS='-ar -o'
1314             fi
1315             ;;
1316         (sco3.2v5*)
1317             CXXLDFLAGS="-u main"
1318             ;;
1319         (solaris2*)
1320             if test "$GXX" != yes ; then
1321                 CXX_AR='$(CXX)'
1322                 CXX_ARFLAGS='-xar -o'
1323             fi
1324             ;;
1325         esac
1326         AC_SUBST(CXXLDFLAGS)
1327         AC_SUBST(CXX_AR)
1328         AC_SUBST(CXX_ARFLAGS)
1329 ])dnl
1330 dnl ---------------------------------------------------------------------------
1331 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1332 dnl -------------------------
1333 dnl For c++, check if iostream uses "std::" namespace.
1334 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1335 AC_CHECK_HEADERS(iostream)
1336 if test x"$ac_cv_header_iostream" = xyes ; then
1337         AC_MSG_CHECKING(if iostream uses std-namespace)
1338         AC_TRY_COMPILE([
1339 #include <iostream>
1340 using std::endl;
1341 using std::cerr;],[
1342 cerr << "testing" << endl;
1343 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1344         AC_MSG_RESULT($cf_iostream_namespace)
1345         if test "$cf_iostream_namespace" = yes ; then
1346                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1347         fi
1348 fi
1349 ])dnl
1350 dnl ---------------------------------------------------------------------------
1351 dnl CF_C_INLINE version: 5 updated: 2015/04/18 08:56:57
1352 dnl -----------
1353 dnl Check if the C compiler supports "inline".
1354 dnl $1 is the name of a shell variable to set if inline is supported
1355 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1356 AC_DEFUN([CF_C_INLINE],[
1357 AC_C_INLINE
1358 $1=
1359 if test "$ac_cv_c_inline" != no ; then
1360         $1=inline
1361         if test "$INTEL_COMPILER" = yes
1362         then
1363                 :
1364         elif test "$CLANG_COMPILER" = yes
1365         then
1366                 :
1367         elif test "$GCC" = yes
1368         then
1369                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1370                 cf_save_CFLAGS=$CFLAGS
1371                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1372                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1373                 [${cf_cv_main_return:-return} foo()],
1374                 [cf_cv_gcc_inline=yes],
1375                 [cf_cv_gcc_inline=no])
1376                 CFLAGS=$cf_save_CFLAGS
1377                 ])
1378                 if test "$cf_cv_gcc_inline" = yes ; then
1379                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1380                 fi
1381         fi
1382 fi
1383 AC_SUBST($1)
1384 ])dnl
1385 dnl ---------------------------------------------------------------------------
1386 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1387 dnl ----------
1388 dnl "dirname" is not portable, so we fake it with a shell script.
1389 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1390 dnl ---------------------------------------------------------------------------
1391 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1392 dnl ---------------
1393 AC_DEFUN([CF_DIRS_TO_MAKE],
1394 [
1395 DIRS_TO_MAKE="lib"
1396 for cf_item in $cf_list_models
1397 do
1398         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1399         for cf_item2 in $DIRS_TO_MAKE
1400         do
1401                 test $cf_item2 = $cf_subdir && break
1402         done
1403         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1404 done
1405 for cf_dir in $DIRS_TO_MAKE
1406 do
1407         test ! -d $cf_dir && mkdir $cf_dir
1408 done
1409 AC_SUBST(DIRS_TO_MAKE)
1410 ])dnl
1411 dnl ---------------------------------------------------------------------------
1412 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1413 dnl ---------------
1414 dnl You can always use "make -n" to see the actual options, but it's hard to
1415 dnl pick out/analyze warning messages when the compile-line is long.
1416 dnl
1417 dnl Sets:
1418 dnl     ECHO_LT - symbol to control if libtool is verbose
1419 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1420 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1421 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1422 dnl     ECHO_CC - symbol to put before any "cc" line
1423 dnl
1424 AC_DEFUN([CF_DISABLE_ECHO],[
1425 AC_MSG_CHECKING(if you want to see long compiling messages)
1426 CF_ARG_DISABLE(echo,
1427         [  --disable-echo          do not display "compiling" commands],
1428         [
1429         ECHO_LT='--silent'
1430         ECHO_LD='@echo linking [$]@;'
1431         RULE_CC='@echo compiling [$]<'
1432         SHOW_CC='@echo compiling [$]@'
1433         ECHO_CC='@'
1434 ],[
1435         ECHO_LT=''
1436         ECHO_LD=''
1437         RULE_CC=''
1438         SHOW_CC=''
1439         ECHO_CC=''
1440 ])
1441 AC_MSG_RESULT($enableval)
1442 AC_SUBST(ECHO_LT)
1443 AC_SUBST(ECHO_LD)
1444 AC_SUBST(RULE_CC)
1445 AC_SUBST(SHOW_CC)
1446 AC_SUBST(ECHO_CC)
1447 ])dnl
1448 dnl ---------------------------------------------------------------------------
1449 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1450 dnl ------------------------
1451 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1452 AC_MSG_CHECKING(if we want to use GNAT projects)
1453 CF_ARG_DISABLE(gnat-projects,
1454         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1455         [enable_gnat_projects=no],
1456         [enable_gnat_projects=yes])
1457 AC_MSG_RESULT($enable_gnat_projects)
1458 ])dnl
1459 dnl ---------------------------------------------------------------------------
1460 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1461 dnl ----------------
1462 dnl Combine no-leak checks with the libraries or tools that are used for the
1463 dnl checks.
1464 AC_DEFUN([CF_DISABLE_LEAKS],[
1465
1466 AC_REQUIRE([CF_WITH_DMALLOC])
1467 AC_REQUIRE([CF_WITH_DBMALLOC])
1468 AC_REQUIRE([CF_WITH_VALGRIND])
1469
1470 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1471 AC_ARG_ENABLE(leaks,
1472         [  --disable-leaks         test: free permanent memory, analyze leaks],
1473         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1474         : ${with_no_leaks:=no})
1475 AC_MSG_RESULT($with_no_leaks)
1476
1477 if test "$with_no_leaks" = yes ; then
1478         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1479         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1480 fi
1481 ])dnl
1482 dnl ---------------------------------------------------------------------------
1483 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1484 dnl --------------------------
1485 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1486 dnl the older "-version-info" feature.  The newer feature allows us to use
1487 dnl version numbering on shared libraries which make them compatible with
1488 dnl various systems.
1489 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1490 [
1491 AC_MSG_CHECKING(if libtool -version-number should be used)
1492 CF_ARG_DISABLE(libtool-version,
1493         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1494         [cf_libtool_version=no],
1495         [cf_libtool_version=yes])
1496 AC_MSG_RESULT($cf_libtool_version)
1497
1498 if test "$cf_libtool_version" = yes ; then
1499         LIBTOOL_VERSION="-version-number"
1500 else
1501         LIBTOOL_VERSION="-version-info"
1502         case "x$VERSION" in
1503         (x)
1504                 AC_MSG_WARN(VERSION was not set)
1505                 ;;
1506         (x*.*.*)
1507                 ABI_VERSION="$VERSION"
1508                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1509                 ;;
1510         (x*:*:*)
1511                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1512                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1513                 ;;
1514         (*)
1515                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1516                 ;;
1517         esac
1518 fi
1519
1520 AC_SUBST(ABI_VERSION)
1521 AC_SUBST(LIBTOOL_VERSION)
1522 ])dnl
1523 dnl ---------------------------------------------------------------------------
1524 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1525 dnl ---------------------
1526 dnl The rpath-hack makes it simpler to build programs, particularly with the
1527 dnl *BSD ports which may have essential libraries in unusual places.  But it
1528 dnl can interfere with building an executable for the base system.  Use this
1529 dnl option in that case.
1530 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1531 [
1532 AC_MSG_CHECKING(if rpath-hack should be disabled)
1533 CF_ARG_DISABLE(rpath-hack,
1534         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1535         [cf_disable_rpath_hack=yes],
1536         [cf_disable_rpath_hack=no])
1537 AC_MSG_RESULT($cf_disable_rpath_hack)
1538 if test "$cf_disable_rpath_hack" = no ; then
1539         CF_RPATH_HACK
1540 fi
1541 ])
1542 dnl ---------------------------------------------------------------------------
1543 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
1544 dnl ------------------
1545 dnl This is the "--enable-pc-files" option, which is available if there is a
1546 dnl pkg-config configuration on the local machine.
1547 AC_DEFUN([CF_ENABLE_PC_FILES],[
1548 AC_REQUIRE([CF_PKG_CONFIG])
1549 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1550
1551 if test "x$PKG_CONFIG" != xnone
1552 then
1553         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1554 else
1555         AC_MSG_CHECKING(if we should install .pc files)
1556 fi
1557
1558 AC_ARG_ENABLE(pc-files,
1559         [  --enable-pc-files       generate and install .pc files for pkg-config],
1560         [enable_pc_files=$enableval],
1561         [enable_pc_files=no])
1562 AC_MSG_RESULT($enable_pc_files)
1563
1564 if test "x$enable_pc_files" != xno
1565 then
1566         MAKE_PC_FILES=
1567         case "x$PKG_CONFIG_LIBDIR" in
1568         (xno|xyes)
1569                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1570                 ;;
1571         (*)
1572                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1573                 ;;
1574         esac
1575 else
1576         MAKE_PC_FILES="#"
1577 fi
1578 AC_SUBST(MAKE_PC_FILES)
1579 ])dnl
1580 dnl ---------------------------------------------------------------------------
1581 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1582 dnl ---------------
1583 dnl Check if the rpath option should be used, setting cache variable
1584 dnl cf_cv_enable_rpath if so.
1585 AC_DEFUN([CF_ENABLE_RPATH],
1586 [
1587 AC_MSG_CHECKING(if rpath option should be used)
1588 AC_ARG_ENABLE(rpath,
1589 [  --enable-rpath          use rpath option when generating shared libraries],
1590 [cf_cv_enable_rpath=$enableval],
1591 [cf_cv_enable_rpath=no])
1592 AC_MSG_RESULT($cf_cv_enable_rpath)
1593 ])dnl
1594 dnl ---------------------------------------------------------------------------
1595 dnl CF_ENABLE_STRING_HACKS version: 4 updated: 2016/09/10 15:33:21
1596 dnl ----------------------
1597 dnl On a few platforms, the compiler and/or loader nags with untruthful
1598 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1599 dnl and implying that most uses of the recommended alternatives are correct.
1600 dnl
1601 dnl Factually speaking, no one has actually counted the number of uses of these
1602 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1603 dnl instances are meaningless compared to the hundreds of millions of lines of
1604 dnl existing C code.
1605 dnl
1606 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1607 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1608 dnl standard - but evolved through phases, and older implementations are likely
1609 dnl to yield surprising results, as documented in manpages on various systems.
1610 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1611 [
1612 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1613 AC_ARG_ENABLE(string-hacks,
1614         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1615         [with_string_hacks=$enableval],
1616         [with_string_hacks=no])
1617 AC_MSG_RESULT($with_string_hacks)
1618
1619 if test "x$with_string_hacks" = "xyes"; then
1620         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1621         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1622         AC_CHECK_FUNC(strlcat,,[
1623                 AC_CHECK_LIB(bsd,strlcat,[
1624                         CF_ADD_LIB(bsd)
1625                         AC_CHECK_HEADERS(bsd/string.h)
1626                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1627                         ])
1628                 ])
1629         AC_CHECK_FUNCS( strlcpy snprintf )
1630 fi
1631 ])dnl
1632 dnl ---------------------------------------------------------------------------
1633 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1634 dnl --------
1635 dnl Check if 'errno' is declared in <errno.h>
1636 AC_DEFUN([CF_ERRNO],
1637 [
1638 CF_CHECK_ERRNO(errno)
1639 ])dnl
1640 dnl ---------------------------------------------------------------------------
1641 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1642 dnl ---------------
1643 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1644 dnl math.h and builtin.h, only for ncurses
1645 AC_DEFUN([CF_ETIP_DEFINES],
1646 [
1647 AC_MSG_CHECKING(for special defines needed for etip.h)
1648 cf_save_CXXFLAGS="$CXXFLAGS"
1649 cf_result="none"
1650
1651 # etip.h includes ncurses.h which includes ncurses_dll.h
1652 # But ncurses_dll.h is generated - fix here.
1653 test -d include || mkdir include
1654 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1655
1656 for cf_math in "" MATH_H
1657 do
1658 for cf_excp in "" MATH_EXCEPTION
1659 do
1660         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1661         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1662         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1663 AC_TRY_COMPILE([
1664 #include <etip.h.in>
1665 ],[],[
1666         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1667         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1668         cf_result="$cf_math $cf_excp"
1669         break 2
1670 ],[])
1671 done
1672 done
1673 AC_MSG_RESULT($cf_result)
1674 CXXFLAGS="$cf_save_CXXFLAGS"
1675 ])
1676 dnl ---------------------------------------------------------------------------
1677 dnl CF_FIND_LINKAGE version: 20 updated: 2015/04/18 08:56:57
1678 dnl ---------------
1679 dnl Find a library (specifically the linkage used in the code fragment),
1680 dnl searching for it if it is not already in the library path.
1681 dnl See also CF_ADD_SEARCHPATH.
1682 dnl
1683 dnl Parameters (4-on are optional):
1684 dnl     $1 = headers for library entrypoint
1685 dnl     $2 = code fragment for library entrypoint
1686 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1687 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1688 dnl     $5 = action to perform if not successful
1689 dnl     $6 = module name, if not the same as the library name
1690 dnl     $7 = extra libraries
1691 dnl
1692 dnl Sets these variables:
1693 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1694 dnl     $cf_cv_header_path_$3 - include-directory if needed
1695 dnl     $cf_cv_library_path_$3 - library-directory if needed
1696 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1697 AC_DEFUN([CF_FIND_LINKAGE],[
1698
1699 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1700 # will be set on completion of the AC_TRY_LINK below.
1701 cf_cv_header_path_$3=
1702 cf_cv_library_path_$3=
1703
1704 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1705
1706 cf_save_LIBS="$LIBS"
1707
1708 AC_TRY_LINK([$1],[$2],[
1709         cf_cv_find_linkage_$3=yes
1710         cf_cv_header_path_$3=/usr/include
1711         cf_cv_library_path_$3=/usr/lib
1712 ],[
1713
1714 LIBS="-l$3 $7 $cf_save_LIBS"
1715
1716 AC_TRY_LINK([$1],[$2],[
1717         cf_cv_find_linkage_$3=yes
1718         cf_cv_header_path_$3=/usr/include
1719         cf_cv_library_path_$3=/usr/lib
1720         cf_cv_library_file_$3="-l$3"
1721 ],[
1722         cf_cv_find_linkage_$3=no
1723         LIBS="$cf_save_LIBS"
1724
1725         CF_VERBOSE(find linkage for $3 library)
1726         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1727
1728         cf_save_CPPFLAGS="$CPPFLAGS"
1729         cf_test_CPPFLAGS="$CPPFLAGS"
1730
1731         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1732         for cf_cv_header_path_$3 in $cf_search
1733         do
1734                 if test -d $cf_cv_header_path_$3 ; then
1735                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1736                         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1737                         AC_TRY_COMPILE([$1],[$2],[
1738                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1739                                 cf_cv_find_linkage_$3=maybe
1740                                 cf_test_CPPFLAGS="$CPPFLAGS"
1741                                 break],[
1742                                 CPPFLAGS="$cf_save_CPPFLAGS"
1743                                 ])
1744                 fi
1745         done
1746
1747         if test "$cf_cv_find_linkage_$3" = maybe ; then
1748
1749                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1750
1751                 cf_save_LIBS="$LIBS"
1752                 cf_save_LDFLAGS="$LDFLAGS"
1753
1754                 ifelse([$6],,,[
1755                 CPPFLAGS="$cf_test_CPPFLAGS"
1756                 LIBS="-l$3 $7 $cf_save_LIBS"
1757                 AC_TRY_LINK([$1],[$2],[
1758                         CF_VERBOSE(... found $3 library in system)
1759                         cf_cv_find_linkage_$3=yes])
1760                         CPPFLAGS="$cf_save_CPPFLAGS"
1761                         LIBS="$cf_save_LIBS"
1762                         ])
1763
1764                 if test "$cf_cv_find_linkage_$3" != yes ; then
1765                         CF_LIBRARY_PATH(cf_search,$3)
1766                         for cf_cv_library_path_$3 in $cf_search
1767                         do
1768                                 if test -d $cf_cv_library_path_$3 ; then
1769                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1770                                         CPPFLAGS="$cf_test_CPPFLAGS"
1771                                         LIBS="-l$3 $7 $cf_save_LIBS"
1772                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1773                                         AC_TRY_LINK([$1],[$2],[
1774                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1775                                         cf_cv_find_linkage_$3=yes
1776                                         cf_cv_library_file_$3="-l$3"
1777                                         break],[
1778                                         CPPFLAGS="$cf_save_CPPFLAGS"
1779                                         LIBS="$cf_save_LIBS"
1780                                         LDFLAGS="$cf_save_LDFLAGS"
1781                                         ])
1782                                 fi
1783                         done
1784                         CPPFLAGS="$cf_save_CPPFLAGS"
1785                         LDFLAGS="$cf_save_LDFLAGS"
1786                 fi
1787
1788         else
1789                 cf_cv_find_linkage_$3=no
1790         fi
1791         ],$7)
1792 ])
1793
1794 LIBS="$cf_save_LIBS"
1795
1796 if test "$cf_cv_find_linkage_$3" = yes ; then
1797 ifelse([$4],,[
1798         CF_ADD_INCDIR($cf_cv_header_path_$3)
1799         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1800         CF_ADD_LIB($3)
1801 ],[$4])
1802 else
1803 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1804 fi
1805 ])dnl
1806 dnl ---------------------------------------------------------------------------
1807 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
1808 dnl ------------------
1809 dnl Find an include-directory with the given leaf-name.  This is useful for
1810 dnl example with FreeBSD ports, which use this convention to distinguish
1811 dnl different versions of the same port.
1812 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1813         CF_SUBDIR_PATH(cf_search,$1,include)
1814         for cf_item in $cf_search
1815         do
1816                 case $cf_item in
1817                 (*/$1)
1818                         CF_ADD_INCDIR($cf_item)
1819                         ;;
1820                 esac
1821         done
1822 ])dnl
1823 dnl ---------------------------------------------------------------------------
1824 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
1825 dnl ------------------
1826 dnl Find a library-directory with the given leaf-name.  This is useful for
1827 dnl example with FreeBSD ports, which use this convention to distinguish
1828 dnl different versions of the same port.
1829 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1830         CF_SUBDIR_PATH(cf_search,$1,lib)
1831         for cf_item in $cf_search
1832         do
1833                 case $cf_item in
1834                 (*/$1)
1835                         CF_ADD_LIBDIR($cf_item)
1836                         ;;
1837                 esac
1838         done
1839 ])dnl
1840 dnl ---------------------------------------------------------------------------
1841 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1842 dnl -----------------
1843 dnl make ADAFLAGS consistent with CFLAGS
1844 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1845         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1846         case "$CFLAGS" in
1847         (*-g*)
1848                 CF_ADD_ADAFLAGS(-g)
1849                 ;;
1850         esac
1851         case "$CFLAGS" in
1852         (*-O*)
1853                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1854                 CF_ADD_ADAFLAGS($cf_O_flag)
1855                 ;;
1856         esac
1857         AC_MSG_RESULT($ADAFLAGS)
1858 ])dnl
1859 dnl ---------------------------------------------------------------------------
1860 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1861 dnl --------------
1862 dnl Forget that we saw the given tool.
1863 AC_DEFUN([CF_FORGET_TOOL],[
1864 unset ac_cv_prog_ac_ct_$1
1865 unset ac_ct_$1
1866 unset $1
1867 ])dnl
1868 dnl ---------------------------------------------------------------------------
1869 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
1870 dnl -------------
1871 dnl Test for dlsym() and related functions, as well as libdl.
1872 dnl
1873 dnl Sets
1874 dnl     $cf_have_dlsym
1875 dnl     $cf_have_libdl
1876 AC_DEFUN([CF_FUNC_DLSYM],[
1877 cf_have_dlsym=no
1878 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1879
1880 cf_have_libdl=no
1881 AC_CHECK_LIB(dl,dlsym,[
1882         cf_have_dlsym=yes
1883         cf_have_libdl=yes])])
1884
1885 if test "$cf_have_dlsym" = yes ; then
1886         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
1887
1888         AC_MSG_CHECKING(whether able to link to dl*() functions)
1889         AC_TRY_LINK([#include <dlfcn.h>],[
1890                 void *obj;
1891                 if ((obj = dlopen("filename", 0)) != 0) {
1892                         if (dlsym(obj, "symbolname") == 0) {
1893                         dlclose(obj);
1894                         }
1895                 }],[
1896                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1897                 AC_MSG_ERROR(Cannot link test program for libdl)])
1898         AC_MSG_RESULT(ok)
1899 else
1900         AC_MSG_ERROR(Cannot find dlsym function)
1901 fi
1902 ])
1903 dnl ---------------------------------------------------------------------------
1904 dnl CF_FUNC_MEMMOVE version: 8 updated: 2012/10/04 20:12:20
1905 dnl ---------------
1906 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1907 dnl is found, add our own version of memmove to the list of objects.
1908 AC_DEFUN([CF_FUNC_MEMMOVE],
1909 [
1910 AC_CHECK_FUNC(memmove,,[
1911 AC_CHECK_FUNC(bcopy,[
1912         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1913                 AC_TRY_RUN([
1914 int main() {
1915         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1916         char temp[40];
1917         bcopy(data, temp, sizeof(data));
1918         bcopy(temp+10, temp, 15);
1919         bcopy(temp+5, temp+15, 10);
1920         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1921 }
1922                 ],
1923                 [cf_cv_good_bcopy=yes],
1924                 [cf_cv_good_bcopy=no],
1925                 [cf_cv_good_bcopy=unknown])
1926                 ])
1927         ],[cf_cv_good_bcopy=no])
1928         if test "$cf_cv_good_bcopy" = yes ; then
1929                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1930         else
1931                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1932         fi
1933 ])])dnl
1934 dnl ---------------------------------------------------------------------------
1935 dnl CF_FUNC_NANOSLEEP version: 4 updated: 2012/10/06 17:56:13
1936 dnl -----------------
1937 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1938 dnl AIX 4.x, provide a non-working version.
1939 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1940 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1941 AC_TRY_RUN([
1942 #include <stdio.h>
1943 #include <errno.h>
1944 #include <time.h>
1945
1946 #ifdef HAVE_SYS_TIME_H
1947 #include <sys/time.h>
1948 #endif
1949
1950 int main() {
1951         struct timespec ts1, ts2;
1952         int code;
1953         ts1.tv_sec  = 0;
1954         ts1.tv_nsec = 750000000;
1955         ts2.tv_sec  = 0;
1956         ts2.tv_nsec = 0;
1957         errno = 0;
1958         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1959         ${cf_cv_main_return:-return}(code != 0);
1960 }
1961 ],
1962         [cf_cv_func_nanosleep=yes],
1963         [cf_cv_func_nanosleep=no],
1964         [cf_cv_func_nanosleep=unknown])])
1965
1966 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1967 ])
1968 dnl ---------------------------------------------------------------------------
1969 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
1970 dnl ---------------
1971 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1972 dnl "util" library as well.
1973 AC_DEFUN([CF_FUNC_OPENPTY],
1974 [
1975 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1976 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1977         cf_save_LIBS="$LIBS"
1978         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
1979         for cf_header in pty.h libutil.h util.h
1980         do
1981         AC_TRY_LINK([
1982 #include <$cf_header>
1983 ],[
1984         int x = openpty((int *)0, (int *)0, (char *)0,
1985                                    (struct termios *)0, (struct winsize *)0);
1986 ],[
1987                 cf_cv_func_openpty=$cf_header
1988                 break
1989 ],[
1990                 cf_cv_func_openpty=no
1991 ])
1992         done
1993         LIBS="$cf_save_LIBS"
1994 ])
1995 ])dnl
1996 dnl ---------------------------------------------------------------------------
1997 dnl CF_FUNC_POLL version: 9 updated: 2015/10/10 13:27:32
1998 dnl ------------
1999 dnl See if the poll function really works.  Some platforms have poll(), but
2000 dnl it does not work for terminals or files.
2001 AC_DEFUN([CF_FUNC_POLL],[
2002 tty 2>&1 >/dev/null || { AC_CHECK_FUNCS(posix_openpt) }
2003 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2004 AC_TRY_RUN([
2005 #include <stdlib.h>
2006 #include <stdio.h>
2007 #include <unistd.h>
2008 #include <fcntl.h>
2009 #ifdef HAVE_POLL_H
2010 #include <poll.h>
2011 #else
2012 #include <sys/poll.h>
2013 #endif
2014 int main(void) {
2015         struct pollfd myfds;
2016         int ret;
2017
2018         /* check for Darwin bug with respect to "devices" */
2019         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2020         if (myfds.fd < 0)
2021                 myfds.fd = 0;
2022         myfds.events = POLLIN;
2023         myfds.revents = 0;
2024
2025         ret = poll(&myfds, 1, 100);
2026
2027         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2028                 ret = -1;
2029         } else {
2030                 int fd = 0;
2031                 if (!isatty(fd)) {
2032                         fd = open("/dev/tty", 2);       /* O_RDWR */
2033                 }
2034 #ifdef HAVE_POSIX_OPENPT
2035                 if (fd < 0) {
2036                         fd = posix_openpt(O_RDWR);
2037                 }
2038 #endif
2039
2040                 if (fd >= 0) {
2041                         /* also check with standard input */
2042                         myfds.fd = fd;
2043                         myfds.events = POLLIN;
2044                         myfds.revents = 0;
2045                         ret = poll(&myfds, 1, 100);
2046                 } else {
2047                         ret = -1;
2048                 }
2049         }
2050         ${cf_cv_main_return:-return}(ret < 0);
2051 }],
2052         [cf_cv_working_poll=yes],
2053         [cf_cv_working_poll=no],
2054         [cf_cv_working_poll=unknown])])
2055 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2056 ])dnl
2057 dnl ---------------------------------------------------------------------------
2058 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2059 dnl ---------------
2060 dnl Some old/broken variations define tcgetattr() only as a macro in
2061 dnl termio(s).h
2062 AC_DEFUN([CF_FUNC_TERMIOS],[
2063 AC_REQUIRE([CF_STRUCT_TERMIOS])
2064 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2065 AC_TRY_LINK([
2066 #include <sys/types.h>
2067 #ifdef HAVE_UNISTD_H
2068 #include <unistd.h>
2069 #endif
2070 #ifdef HAVE_TERMIOS_H
2071 #include <termios.h>
2072 #define TTY struct termios
2073 #else
2074 #ifdef HAVE_TERMIO_H
2075 #include <termio.h>
2076 #define TTY struct termio
2077 #endif
2078 #endif
2079 ],[
2080 TTY foo;
2081 tcgetattr(1, &foo);],
2082 [cf_cv_have_tcgetattr=yes],
2083 [cf_cv_have_tcgetattr=no])])
2084 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2085 ])dnl
2086 dnl ---------------------------------------------------------------------------
2087 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
2088 dnl ---------------
2089 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2090 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2091 dnl other functions.
2092 AC_DEFUN([CF_FUNC_VSSCANF],
2093 [
2094 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2095 AC_TRY_LINK([
2096 #include <stdarg.h>
2097 #include <stdio.h>],[
2098         va_list ap;
2099         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2100 AC_TRY_LINK([
2101 #include <stdarg.h>
2102 #include <stdio.h>],[
2103         FILE strbuf;
2104         char *str = "from";
2105
2106         strbuf._flag = _IOREAD;
2107         strbuf._ptr = strbuf._base = (unsigned char *) str;
2108         strbuf._cnt = strlen(str);
2109         strbuf._file = _NFILE;
2110         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2111 AC_TRY_LINK([
2112 #include <stdarg.h>
2113 #include <stdio.h>],[
2114         FILE strbuf;
2115         char *str = "from";
2116
2117         strbuf._flag = _IOREAD;
2118         strbuf._ptr = strbuf._base = (unsigned char *) str;
2119         strbuf._cnt = strlen(str);
2120         strbuf._file = _NFILE;
2121         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2122 cf_cv_func_vsscanf=no])])])])
2123
2124 case $cf_cv_func_vsscanf in
2125 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2126 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2127 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2128 esac
2129
2130 ])dnl
2131 dnl ---------------------------------------------------------------------------
2132 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
2133 dnl -----------------
2134 dnl Test for availability of useful gcc __attribute__ directives to quiet
2135 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2136 dnl to documentation, unrecognized directives cause older compilers to barf.
2137 AC_DEFUN([CF_GCC_ATTRIBUTES],
2138 [
2139 if test "$GCC" = yes
2140 then
2141 cat > conftest.i <<EOF
2142 #ifndef GCC_PRINTF
2143 #define GCC_PRINTF 0
2144 #endif
2145 #ifndef GCC_SCANF
2146 #define GCC_SCANF 0
2147 #endif
2148 #ifndef GCC_NORETURN
2149 #define GCC_NORETURN /* nothing */
2150 #endif
2151 #ifndef GCC_UNUSED
2152 #define GCC_UNUSED /* nothing */
2153 #endif
2154 EOF
2155 if test "$GCC" = yes
2156 then
2157         AC_CHECKING([for $CC __attribute__ directives])
2158 cat > conftest.$ac_ext <<EOF
2159 #line __oline__ "${as_me:-configure}"
2160 #include "confdefs.h"
2161 #include "conftest.h"
2162 #include "conftest.i"
2163 #if     GCC_PRINTF
2164 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2165 #else
2166 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2167 #endif
2168 #if     GCC_SCANF
2169 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2170 #else
2171 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2172 #endif
2173 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2174 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
2175 extern void foo(void) GCC_NORETURN;
2176 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
2177 EOF
2178         cf_printf_attribute=no
2179         cf_scanf_attribute=no
2180         for cf_attribute in scanf printf unused noreturn
2181         do
2182                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2183                 cf_directive="__attribute__(($cf_attribute))"
2184                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2185
2186                 case $cf_attribute in
2187                 (printf)
2188                         cf_printf_attribute=yes
2189                         cat >conftest.h <<EOF
2190 #define GCC_$cf_ATTRIBUTE 1
2191 EOF
2192                         ;;
2193                 (scanf)
2194                         cf_scanf_attribute=yes
2195                         cat >conftest.h <<EOF
2196 #define GCC_$cf_ATTRIBUTE 1
2197 EOF
2198                         ;;
2199                 (*)
2200                         cat >conftest.h <<EOF
2201 #define GCC_$cf_ATTRIBUTE $cf_directive
2202 EOF
2203                         ;;
2204                 esac
2205
2206                 if AC_TRY_EVAL(ac_compile); then
2207                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2208                         cat conftest.h >>confdefs.h
2209                         case $cf_attribute in
2210                         (noreturn)
2211                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2212                                 ;;
2213                         (printf)
2214                                 cf_value='/* nothing */'
2215                                 if test "$cf_printf_attribute" != no ; then
2216                                         cf_value='__attribute__((format(printf,fmt,var)))'
2217                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2218                                 fi
2219                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2220                                 ;;
2221                         (scanf)
2222                                 cf_value='/* nothing */'
2223                                 if test "$cf_scanf_attribute" != no ; then
2224                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2225                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2226                                 fi
2227                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2228                                 ;;
2229                         (unused)
2230                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2231                                 ;;
2232                         esac
2233                 fi
2234         done
2235 else
2236         fgrep define conftest.i >>confdefs.h
2237 fi
2238 rm -rf conftest*
2239 fi
2240 ])dnl
2241 dnl ---------------------------------------------------------------------------
2242 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
2243 dnl --------------
2244 dnl Find version of gcc
2245 AC_DEFUN([CF_GCC_VERSION],[
2246 AC_REQUIRE([AC_PROG_CC])
2247 GCC_VERSION=none
2248 if test "$GCC" = yes ; then
2249         AC_MSG_CHECKING(version of $CC)
2250         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2251         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2252         AC_MSG_RESULT($GCC_VERSION)
2253 fi
2254 ])dnl
2255 dnl ---------------------------------------------------------------------------
2256 dnl CF_GCC_WARNINGS version: 32 updated: 2015/04/12 15:39:00
2257 dnl ---------------
2258 dnl Check if the compiler supports useful warning options.  There's a few that
2259 dnl we don't use, simply because they're too noisy:
2260 dnl
2261 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2262 dnl     -Wredundant-decls (system headers make this too noisy)
2263 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2264 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2265 dnl             is enabled for ncurses using "--enable-const".
2266 dnl     -pedantic
2267 dnl
2268 dnl Parameter:
2269 dnl     $1 is an optional list of gcc warning flags that a particular
2270 dnl             application might want to use, e.g., "no-unused" for
2271 dnl             -Wno-unused
2272 dnl Special:
2273 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2274 dnl
2275 AC_DEFUN([CF_GCC_WARNINGS],
2276 [
2277 AC_REQUIRE([CF_GCC_VERSION])
2278 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2279 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2280
2281 cat > conftest.$ac_ext <<EOF
2282 #line __oline__ "${as_me:-configure}"
2283 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2284 EOF
2285
2286 if test "$INTEL_COMPILER" = yes
2287 then
2288 # The "-wdXXX" options suppress warnings:
2289 # remark #1419: external declaration in primary source file
2290 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2291 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2292 # remark #193: zero used for undefined preprocessing identifier
2293 # remark #593: variable "curs_sb_left_arrow" was set but never used
2294 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2295 # remark #869: parameter "tw" was never referenced
2296 # remark #981: operands are evaluated in unspecified order
2297 # warning #279: controlling expression is constant
2298
2299         AC_CHECKING([for $CC warning options])
2300         cf_save_CFLAGS="$CFLAGS"
2301         EXTRA_CFLAGS="-Wall"
2302         for cf_opt in \
2303                 wd1419 \
2304                 wd1683 \
2305                 wd1684 \
2306                 wd193 \
2307                 wd593 \
2308                 wd279 \
2309                 wd810 \
2310                 wd869 \
2311                 wd981
2312         do
2313                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2314                 if AC_TRY_EVAL(ac_compile); then
2315                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2316                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2317                 fi
2318         done
2319         CFLAGS="$cf_save_CFLAGS"
2320
2321 elif test "$GCC" = yes
2322 then
2323         AC_CHECKING([for $CC warning options])
2324         cf_save_CFLAGS="$CFLAGS"
2325         EXTRA_CFLAGS=
2326         cf_warn_CONST=""
2327         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2328         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2329         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2330         for cf_opt in W Wall \
2331                 Wbad-function-cast \
2332                 Wcast-align \
2333                 Wcast-qual \
2334                 Wdeclaration-after-statement \
2335                 Wextra \
2336                 Winline \
2337                 Wmissing-declarations \
2338                 Wmissing-prototypes \
2339                 Wnested-externs \
2340                 Wpointer-arith \
2341                 Wshadow \
2342                 Wstrict-prototypes \
2343                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2344         do
2345                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2346                 if AC_TRY_EVAL(ac_compile); then
2347                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2348                         case $cf_opt in
2349                         (Wcast-qual)
2350                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2351                                 ;;
2352                         (Winline)
2353                                 case $GCC_VERSION in
2354                                 ([[34]].*)
2355                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2356                                         continue;;
2357                                 esac
2358                                 ;;
2359                         (Wpointer-arith)
2360                                 case $GCC_VERSION in
2361                                 ([[12]].*)
2362                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2363                                         continue;;
2364                                 esac
2365                                 ;;
2366                         esac
2367                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2368                 fi
2369         done
2370         CFLAGS="$cf_save_CFLAGS"
2371 fi
2372 rm -rf conftest*
2373
2374 AC_SUBST(EXTRA_CFLAGS)
2375 ])dnl
2376 dnl ---------------------------------------------------------------------------
2377 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2378 dnl ----------------
2379 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2380 dnl unistd.h or (nonstandard) in getopt.h
2381 AC_DEFUN([CF_GETOPT_HEADER],
2382 [
2383 AC_HAVE_HEADERS(unistd.h getopt.h)
2384 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2385 cf_cv_getopt_header=none
2386 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2387 do
2388 AC_TRY_COMPILE([
2389 #include <$cf_header>],
2390 [int x = optind; char *y = optarg],
2391 [cf_cv_getopt_header=$cf_header
2392  break])
2393 done
2394 ])
2395 if test $cf_cv_getopt_header != none ; then
2396         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2397 fi
2398 if test $cf_cv_getopt_header = getopt.h ; then
2399         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2400 fi
2401 ])dnl
2402 dnl ---------------------------------------------------------------------------
2403 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2404 dnl -----------------
2405 AC_DEFUN([CF_GNATPREP_OPT_T],[
2406 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2407 cf_cv_gnatprep_opt_t=no
2408 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2409 ])
2410 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2411 AC_SUBST(GNATPREP_OPTS)
2412 ])dnl
2413 dnl ---------------------------------------------------------------------------
2414 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
2415 dnl ----------------
2416 AC_DEFUN([CF_GNAT_GENERICS],
2417 [
2418 AC_REQUIRE([CF_GNAT_VERSION])
2419
2420 AC_MSG_CHECKING(if GNAT supports generics)
2421 case $cf_gnat_version in
2422 (3.[[1-9]]*|[[4-9]].*)
2423         cf_gnat_generics=yes
2424         ;;
2425 (*)
2426         cf_gnat_generics=no
2427         ;;
2428 esac
2429 AC_MSG_RESULT($cf_gnat_generics)
2430
2431 if test "$cf_gnat_generics" = yes
2432 then
2433         cf_compile_generics=generics
2434         cf_generic_objects="\${GENOBJS}"
2435 else
2436         cf_compile_generics=
2437         cf_generic_objects=
2438 fi
2439
2440 AC_SUBST(cf_compile_generics)
2441 AC_SUBST(cf_generic_objects)
2442 ])dnl
2443 dnl ---------------------------------------------------------------------------
2444 dnl CF_GNAT_PROJECTS version: 8 updated: 2015/04/17 21:13:04
2445 dnl ----------------
2446 dnl GNAT projects are configured with ".gpr" project files.
2447 dnl GNAT libraries are a further development, using the project feature.
2448 AC_DEFUN([CF_GNAT_PROJECTS],
2449 [
2450 AC_REQUIRE([CF_GNAT_VERSION])
2451 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2452
2453 cf_gnat_libraries=no
2454 cf_gnat_projects=no
2455
2456 if test "$enable_gnat_projects" != no ; then
2457 AC_MSG_CHECKING(if GNAT supports project files)
2458 case $cf_gnat_version in
2459 (3.[[0-9]]*)
2460         ;;
2461 (*)
2462         case $cf_cv_system_name in
2463         (cygwin*|msys*)
2464                 ;;
2465         (*)
2466                 mkdir conftest.src conftest.bin conftest.lib
2467                 cd conftest.src
2468                 rm -rf conftest* *~conftest*
2469                 cat >>library.gpr <<CF_EOF
2470 project Library is
2471   Kind := External ("LIB_KIND");
2472   for Library_Name use "ConfTest";
2473   for Object_Dir use ".";
2474   for Library_ALI_Dir use External("LIBRARY_DIR");
2475   for Library_Version use External ("SONAME");
2476   for Library_Kind use Kind;
2477   for Library_Dir use External("BUILD_DIR");
2478   Source_Dir := External ("SOURCE_DIR");
2479   for Source_Dirs use (Source_Dir);
2480 end Library;
2481 CF_EOF
2482                 cat >>confpackage.ads <<CF_EOF
2483 package ConfPackage is
2484    procedure conftest;
2485 end ConfPackage;
2486 CF_EOF
2487                 cat >>confpackage.adb <<CF_EOF
2488 with Text_IO;
2489 package body ConfPackage is
2490    procedure conftest is
2491    begin
2492       Text_IO.Put ("Hello World");
2493       Text_IO.New_Line;
2494    end conftest;
2495 end ConfPackage;
2496 CF_EOF
2497                 if ( $cf_ada_make $ADAFLAGS \
2498                                 -Plibrary.gpr \
2499                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2500                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2501                                 -XSOURCE_DIR=`pwd` \
2502                                 -XSONAME=libConfTest.so.1 \
2503                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2504                         cf_gnat_projects=yes
2505                 fi
2506                 cd ..
2507                 if test -f conftest.lib/confpackage.ali
2508                 then
2509                         cf_gnat_libraries=yes
2510                 fi
2511                 rm -rf conftest* *~conftest*
2512                 ;;
2513         esac
2514         ;;
2515 esac
2516 AC_MSG_RESULT($cf_gnat_projects)
2517 fi # enable_gnat_projects
2518
2519 if test $cf_gnat_projects = yes
2520 then
2521         AC_MSG_CHECKING(if GNAT supports libraries)
2522         AC_MSG_RESULT($cf_gnat_libraries)
2523 fi
2524
2525 if test "$cf_gnat_projects" = yes
2526 then
2527         USE_OLD_MAKERULES="#"
2528         USE_GNAT_PROJECTS=""
2529 else
2530         USE_OLD_MAKERULES=""
2531         USE_GNAT_PROJECTS="#"
2532 fi
2533
2534 if test "$cf_gnat_libraries" = yes
2535 then
2536         USE_GNAT_LIBRARIES=""
2537 else
2538         USE_GNAT_LIBRARIES="#"
2539 fi
2540
2541 AC_SUBST(USE_OLD_MAKERULES)
2542 AC_SUBST(USE_GNAT_PROJECTS)
2543 AC_SUBST(USE_GNAT_LIBRARIES)
2544 ])dnl
2545 dnl ---------------------------------------------------------------------------
2546 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2547 dnl --------------
2548 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2549 dnl is noted that gnat may compile a tasking unit even for configurations which
2550 dnl fail at runtime.
2551 AC_DEFUN([CF_GNAT_SIGINT],[
2552 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2553 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2554
2555 package ConfTest is
2556
2557    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2558    pragma Unreserve_All_Interrupts;
2559    pragma Warnings (On);
2560
2561    protected Process is
2562       procedure Stop;
2563       function Continue return Boolean;
2564       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2565    private
2566       Done : Boolean := False;
2567    end Process;
2568
2569 end ConfTest;],
2570 [package body ConfTest is
2571    protected body Process is
2572       procedure Stop is
2573       begin
2574          Done := True;
2575       end Stop;
2576       function Continue return Boolean is
2577       begin
2578          return not Done;
2579       end Continue;
2580    end Process;
2581 end ConfTest;],
2582         [cf_cv_gnat_sigint=yes],
2583         [cf_cv_gnat_sigint=no])])
2584
2585 if test $cf_cv_gnat_sigint = yes ; then
2586         USE_GNAT_SIGINT=""
2587 else
2588         USE_GNAT_SIGINT="#"
2589 fi
2590 AC_SUBST(USE_GNAT_SIGINT)
2591 ])dnl
2592 dnl ---------------------------------------------------------------------------
2593 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2594 dnl ----------------
2595 dnl Verify that a test program compiles/links with GNAT.
2596 dnl $cf_ada_make is set to the program that compiles/links
2597 dnl $ADAFLAGS may be set to the GNAT flags.
2598 dnl
2599 dnl $1 is the text of the spec
2600 dnl $2 is the text of the body
2601 dnl $3 is the shell command to execute if successful
2602 dnl $4 is the shell command to execute if not successful
2603 AC_DEFUN([CF_GNAT_TRY_LINK],
2604 [
2605 rm -rf conftest* *~conftest*
2606 cat >>conftest.ads <<CF_EOF
2607 $1
2608 CF_EOF
2609 cat >>conftest.adb <<CF_EOF
2610 $2
2611 CF_EOF
2612 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2613 ifelse($3,,      :,[      $3])
2614 ifelse($4,,,[else
2615    $4])
2616 fi
2617 rm -rf conftest* *~conftest*
2618 ])dnl
2619 dnl ---------------------------------------------------------------------------
2620 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2621 dnl ---------------
2622 dnl Verify that a test program compiles and runs with GNAT
2623 dnl $cf_ada_make is set to the program that compiles/links
2624 dnl $ADAFLAGS may be set to the GNAT flags.
2625 dnl
2626 dnl $1 is the text of the spec
2627 dnl $2 is the text of the body
2628 dnl $3 is the shell command to execute if successful
2629 dnl $4 is the shell command to execute if not successful
2630 AC_DEFUN([CF_GNAT_TRY_RUN],
2631 [
2632 rm -rf conftest* *~conftest*
2633 cat >>conftest.ads <<CF_EOF
2634 $1
2635 CF_EOF
2636 cat >>conftest.adb <<CF_EOF
2637 $2
2638 CF_EOF
2639 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2640    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2641 ifelse($3,,      :,[      $3])
2642 ifelse($4,,,[   else
2643       $4])
2644    fi
2645 ifelse($4,,,[else
2646    $4])
2647 fi
2648 rm -rf conftest* *~conftest*
2649 ])dnl
2650 dnl ---------------------------------------------------------------------------
2651 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
2652 dnl ---------------
2653 dnl Verify version of GNAT.
2654 AC_DEFUN([CF_GNAT_VERSION],
2655 [
2656 AC_MSG_CHECKING(for gnat version)
2657 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2658         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2659         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2660 AC_MSG_RESULT($cf_gnat_version)
2661
2662 case $cf_gnat_version in
2663 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
2664         cf_cv_prog_gnat_correct=yes
2665         ;;
2666 (*)
2667         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2668         cf_cv_prog_gnat_correct=no
2669         ;;
2670 esac
2671 ])
2672 dnl ---------------------------------------------------------------------------
2673 dnl CF_GNU_SOURCE version: 7 updated: 2016/08/05 05:15:37
2674 dnl -------------
2675 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2676 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2677 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2678 dnl since it is interwoven with GNU extensions.
2679 dnl
2680 dnl Well, yes we could work around it...
2681 AC_DEFUN([CF_GNU_SOURCE],
2682 [
2683 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2684 AC_TRY_COMPILE([#include <sys/types.h>],[
2685 #ifndef _XOPEN_SOURCE
2686 make an error
2687 #endif],
2688         [cf_cv_gnu_source=no],
2689         [cf_save="$CPPFLAGS"
2690          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2691          AC_TRY_COMPILE([#include <sys/types.h>],[
2692 #ifdef _XOPEN_SOURCE
2693 make an error
2694 #endif],
2695         [cf_cv_gnu_source=no],
2696         [cf_cv_gnu_source=yes])
2697         CPPFLAGS="$cf_save"
2698         ])
2699 ])
2700
2701 if test "$cf_cv_gnu_source" = yes
2702 then
2703 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
2704 CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2705         AC_TRY_COMPILE([#include <sys/types.h>],[
2706 #ifdef _DEFAULT_SOURCE
2707 make an error
2708 #endif],
2709                 [cf_cv_default_source=no],
2710                 [cf_cv_default_source=yes])
2711         ])
2712 test "$cf_cv_default_source" = yes && CPPFLAGS="$CPPFLAGS -D_DEFAULT_SOURCE"
2713 fi
2714 ])dnl
2715 dnl ---------------------------------------------------------------------------
2716 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
2717 dnl --------------
2718 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2719 dnl problem :-).  If we have the compiler but no library, we'll be able to
2720 dnl configure, but won't be able to build the c++ demo program.
2721 AC_DEFUN([CF_GPP_LIBRARY],
2722 [
2723 cf_cxx_library=unknown
2724 case $cf_cv_system_name in
2725 (os2*)
2726         cf_gpp_libname=gpp
2727         ;;
2728 (*)
2729         cf_gpp_libname=g++
2730         ;;
2731 esac
2732 if test "$GXX" = yes; then
2733         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2734         cf_save="$LIBS"
2735         CF_ADD_LIB($cf_gpp_libname)
2736         AC_TRY_LINK([
2737 #include <$cf_gpp_libname/builtin.h>
2738         ],
2739         [two_arg_error_handler_t foo2 = lib_error_handler],
2740         [cf_cxx_library=yes
2741          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2742          if test "$cf_gpp_libname" = cpp ; then
2743             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2744          else
2745             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2746          fi],
2747         [AC_TRY_LINK([
2748 #include <builtin.h>
2749         ],
2750         [two_arg_error_handler_t foo2 = lib_error_handler],
2751         [cf_cxx_library=yes
2752          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2753          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2754         [cf_cxx_library=no])])
2755         LIBS="$cf_save"
2756         AC_MSG_RESULT($cf_cxx_library)
2757 fi
2758 ])dnl
2759 dnl ---------------------------------------------------------------------------
2760 dnl CF_GXX_VERSION version: 7 updated: 2012/06/16 14:55:39
2761 dnl --------------
2762 dnl Check for version of g++
2763 AC_DEFUN([CF_GXX_VERSION],[
2764 AC_REQUIRE([AC_PROG_CPP])
2765 GXX_VERSION=none
2766 if test "$GXX" = yes; then
2767         AC_MSG_CHECKING(version of ${CXX:-g++})
2768         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2769         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2770         AC_MSG_RESULT($GXX_VERSION)
2771 fi
2772 ])dnl
2773 dnl ---------------------------------------------------------------------------
2774 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
2775 dnl ---------------
2776 dnl Check if the compiler supports useful warning options.
2777 dnl
2778 dnl Most of gcc's options apply to g++, except:
2779 dnl     -Wbad-function-cast
2780 dnl     -Wmissing-declarations
2781 dnl     -Wnested-externs
2782 dnl
2783 dnl Omit a few (for now):
2784 dnl     -Winline
2785 dnl
2786 dnl Parameter:
2787 dnl     $1 is an optional list of g++ warning flags that a particular
2788 dnl             application might want to use, e.g., "no-unused" for
2789 dnl             -Wno-unused
2790 dnl Special:
2791 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2792 dnl
2793 AC_DEFUN([CF_GXX_WARNINGS],
2794 [
2795
2796 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2797 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2798
2799 AC_REQUIRE([CF_GXX_VERSION])
2800
2801 AC_LANG_SAVE
2802 AC_LANG_CPLUSPLUS
2803
2804 cat > conftest.$ac_ext <<EOF
2805 #line __oline__ "configure"
2806 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2807 EOF
2808
2809 if test "$INTEL_CPLUSPLUS" = yes
2810 then
2811 # The "-wdXXX" options suppress warnings:
2812 # remark #1419: external declaration in primary source file
2813 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2814 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2815 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2816 # remark #193: zero used for undefined preprocessing identifier
2817 # remark #593: variable "curs_sb_left_arrow" was set but never used
2818 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2819 # remark #869: parameter "tw" was never referenced
2820 # remark #981: operands are evaluated in unspecified order
2821 # warning #269: invalid format string conversion
2822
2823         AC_CHECKING([for $CC warning options])
2824         cf_save_CXXFLAGS="$CXXFLAGS"
2825         EXTRA_CXXFLAGS="-Wall"
2826         for cf_opt in \
2827                 wd1419 \
2828                 wd1682 \
2829                 wd1683 \
2830                 wd1684 \
2831                 wd193 \
2832                 wd279 \
2833                 wd593 \
2834                 wd810 \
2835                 wd869 \
2836                 wd981
2837         do
2838                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2839                 if AC_TRY_EVAL(ac_compile); then
2840                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2841                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2842                 fi
2843         done
2844         CXXFLAGS="$cf_save_CXXFLAGS"
2845
2846 elif test "$GXX" = yes
2847 then
2848         AC_CHECKING([for $CXX warning options])
2849         cf_save_CXXFLAGS="$CXXFLAGS"
2850         EXTRA_CXXFLAGS="-W -Wall"
2851         cf_gxx_extra_warnings=""
2852         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2853         case "$GCC_VERSION" in
2854         ([[1-2]].*)
2855                 ;;
2856         (*)
2857                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2858                 ;;
2859         esac
2860         for cf_opt in \
2861                 Wabi \
2862                 fabi-version=0 \
2863                 Wextra \
2864                 Wignored-qualifiers \
2865                 Wlogical-op \
2866                 Woverloaded-virtual \
2867                 Wsign-promo \
2868                 Wsynth \
2869                 Wold-style-cast \
2870                 Wcast-align \
2871                 Wcast-qual \
2872                 Wpointer-arith \
2873                 Wshadow \
2874                 Wundef $cf_gxx_extra_warnings $1
2875         do
2876                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2877                 if AC_TRY_EVAL(ac_compile); then
2878                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2879                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2880                 else
2881                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2882                 fi
2883         done
2884         CXXFLAGS="$cf_save_CXXFLAGS"
2885 fi
2886
2887 rm -rf conftest*
2888 AC_LANG_RESTORE
2889 AC_SUBST(EXTRA_CXXFLAGS)
2890 ])dnl
2891 dnl ---------------------------------------------------------------------------
2892 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
2893 dnl ------------
2894 dnl Look for an instance of the Berkeley hashed database.
2895 dnl
2896 dnl $1 = optional parameter, to specify install-prefix for the database.
2897 AC_DEFUN([CF_HASHED_DB],
2898 [
2899 ifelse([$1],,,[
2900 case $1 in
2901 (yes|*able*)
2902         ;;
2903 (*)
2904         if test -d "$1" ; then
2905                 CF_ADD_INCDIR($1/include)
2906                 CF_ADD_LIBDIR($1/lib)
2907         else
2908                 case "$1" in
2909                 (./*|../*|/*)
2910                         AC_MSG_WARN(no such directory $1)
2911                         ;;
2912                 (*)
2913                         CF_FIND_SUB_INCDIR($1)
2914                         CF_FIND_SUB_LIBDIR($1)
2915                         ;;
2916                 esac
2917         fi
2918 esac
2919 ])
2920 AC_CHECK_HEADER(db.h,[
2921 CF_HASHED_DB_VERSION
2922 if test "$cf_cv_hashed_db_version" = unknown ; then
2923         AC_MSG_ERROR(Cannot determine version of db)
2924 else
2925         CF_HASHED_DB_LIBS
2926         if test "$cf_cv_hashed_db_libs" = unknown ; then
2927                 AC_MSG_ERROR(Cannot determine library for db)
2928         elif test "$cf_cv_hashed_db_libs" != default ; then
2929                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2930         fi
2931 fi
2932 ],[
2933         AC_MSG_ERROR(Cannot find db.h)
2934 ])
2935 ])dnl
2936 dnl ---------------------------------------------------------------------------
2937 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2938 dnl -----------------
2939 dnl Given that we have the header and version for hashed database, find the
2940 dnl library information.
2941 AC_DEFUN([CF_HASHED_DB_LIBS],
2942 [
2943 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2944 cf_cv_hashed_db_libs=unknown
2945 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2946 do
2947         cf_save_libs="$LIBS"
2948         if test -n "$cf_db_libs"; then
2949                 CF_ADD_LIB($cf_db_libs)
2950         fi
2951         CF_MSG_LOG(checking for library "$cf_db_libs")
2952         AC_TRY_LINK([
2953 $ac_includes_default
2954 #include <db.h>
2955 ],[
2956         char *path = "/tmp/foo";
2957 #ifdef DB_VERSION_MAJOR
2958 #if DB_VERSION_MAJOR >= 4
2959         DB *result = 0;
2960         db_create(&result, NULL, 0);
2961         result->open(result,
2962                 NULL,
2963                 path,
2964                 path,
2965                 DB_HASH,
2966                 DB_CREATE,
2967                 0644);
2968 #elif DB_VERSION_MAJOR >= 3
2969         DB *result = 0;
2970         db_create(&result, NULL, 0);
2971         result->open(result,
2972                 path,
2973                 path,
2974                 DB_HASH,
2975                 DB_CREATE,
2976                 0644);
2977 #elif DB_VERSION_MAJOR >= 2
2978         DB *result = 0;
2979         db_open(path,
2980                 DB_HASH,
2981                 DB_CREATE,
2982                 0644,
2983                 (DB_ENV *) 0,
2984                 (DB_INFO *) 0,
2985                 &result);
2986 #endif /* DB_VERSION_MAJOR */
2987 #else
2988         DB *result = dbopen(path,
2989                      2,
2990                      0644,
2991                      DB_HASH,
2992                      0);
2993 #endif
2994         ${cf_cv_main_return:-return}(result != 0)
2995 ],[
2996         if test -n "$cf_db_libs" ; then
2997                 cf_cv_hashed_db_libs=$cf_db_libs
2998         else
2999                 cf_cv_hashed_db_libs=default
3000         fi
3001         LIBS="$cf_save_libs"
3002         break
3003 ])
3004         LIBS="$cf_save_libs"
3005 done
3006 ])
3007 ])dnl
3008 dnl ---------------------------------------------------------------------------
3009 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3010 dnl --------------------
3011 dnl Given that we have the header file for hashed database, find the version
3012 dnl information.
3013 AC_DEFUN([CF_HASHED_DB_VERSION],
3014 [
3015 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3016 cf_cv_hashed_db_version=unknown
3017
3018 for cf_db_version in 1 2 3 4 5 6
3019 do
3020         CF_MSG_LOG(checking for db version $cf_db_version)
3021         AC_TRY_COMPILE([
3022 $ac_includes_default
3023 #include <db.h>
3024
3025 #ifdef DB_VERSION_MAJOR
3026         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3027 #if $cf_db_version == DB_VERSION_MAJOR
3028         /* ok */
3029 #else
3030         make an error
3031 #endif
3032 #else
3033 #if $cf_db_version == 1
3034         /* ok: assuming this is DB 1.8.5 */
3035 #else
3036         make an error
3037 #endif
3038 #endif
3039 ],[DBT *foo = 0],[
3040         cf_cv_hashed_db_version=$cf_db_version
3041         break
3042         ])
3043 done
3044 ])
3045 ])dnl
3046 dnl ---------------------------------------------------------------------------
3047 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
3048 dnl --------------
3049 dnl Construct a search-list of directories for a nonstandard header-file
3050 dnl
3051 dnl Parameters
3052 dnl     $1 = the variable to return as result
3053 dnl     $2 = the package name
3054 AC_DEFUN([CF_HEADER_PATH],
3055 [
3056 $1=
3057
3058 # collect the current set of include-directories from compiler flags
3059 cf_header_path_list=""
3060 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3061         for cf_header_path in $CPPFLAGS $CFLAGS
3062         do
3063                 case $cf_header_path in
3064                 (-I*)
3065                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3066                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3067                         cf_header_path_list="$cf_header_path_list [$]$1"
3068                         ;;
3069                 esac
3070         done
3071 fi
3072
3073 # add the variations for the package we are looking for
3074 CF_SUBDIR_PATH($1,$2,include)
3075
3076 test "$includedir" != NONE && \
3077 test "$includedir" != "/usr/include" && \
3078 test -d "$includedir" && {
3079         test -d $includedir &&    $1="[$]$1 $includedir"
3080         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
3081 }
3082
3083 test "$oldincludedir" != NONE && \
3084 test "$oldincludedir" != "/usr/include" && \
3085 test -d "$oldincludedir" && {
3086         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
3087         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
3088 }
3089
3090 $1="[$]$1 $cf_header_path_list"
3091 ])dnl
3092 dnl ---------------------------------------------------------------------------
3093 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
3094 dnl ---------------
3095 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3096 AC_DEFUN([CF_HELP_MESSAGE],
3097 [AC_DIVERT_HELP([$1])dnl
3098 ])dnl
3099 dnl ---------------------------------------------------------------------------
3100 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3101 dnl ---------------
3102 dnl Construct the list of include-options according to whether we're building
3103 dnl in the source directory or using '--srcdir=DIR' option.
3104 AC_DEFUN([CF_INCLUDE_DIRS],
3105 [
3106 if test "$srcdir" != "."; then
3107         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3108 fi
3109 CPPFLAGS="-I../include $CPPFLAGS"
3110 if test "$srcdir" != "."; then
3111         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3112 fi
3113 CPPFLAGS="-I. $CPPFLAGS"
3114 AC_SUBST(CPPFLAGS)
3115 ])dnl
3116 dnl ---------------------------------------------------------------------------
3117 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
3118 dnl -----------------
3119 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3120 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3121 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3122 dnl
3123 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3124 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3125 dnl the wrappers for gcc and g++ warnings.
3126 dnl
3127 dnl $1 = GCC (default) or GXX
3128 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3129 dnl $3 = CFLAGS (default) or CXXFLAGS
3130 AC_DEFUN([CF_INTEL_COMPILER],[
3131 AC_REQUIRE([AC_CANONICAL_HOST])
3132 ifelse([$2],,INTEL_COMPILER,[$2])=no
3133
3134 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3135         case $host_os in
3136         (linux*|gnu*)
3137                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3138                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3139                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3140                 AC_TRY_COMPILE([],[
3141 #ifdef __INTEL_COMPILER
3142 #else
3143 make an error
3144 #endif
3145 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3146 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3147 ],[])
3148                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3149                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3150                 ;;
3151         esac
3152 fi
3153 ])dnl
3154 dnl ---------------------------------------------------------------------------
3155 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3156 dnl ----------
3157 dnl Check if we have either a function or macro for 'isascii()'.
3158 AC_DEFUN([CF_ISASCII],
3159 [
3160 AC_MSG_CHECKING(for isascii)
3161 AC_CACHE_VAL(cf_cv_have_isascii,[
3162         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3163         [cf_cv_have_isascii=yes],
3164         [cf_cv_have_isascii=no])
3165 ])dnl
3166 AC_MSG_RESULT($cf_cv_have_isascii)
3167 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3168 ])dnl
3169 dnl ---------------------------------------------------------------------------
3170 dnl CF_LARGEFILE version: 9 updated: 2015/04/18 08:56:57
3171 dnl ------------
3172 dnl Add checks for large file support.
3173 AC_DEFUN([CF_LARGEFILE],[
3174 ifdef([AC_FUNC_FSEEKO],[
3175         AC_SYS_LARGEFILE
3176         if test "$enable_largefile" != no ; then
3177         AC_FUNC_FSEEKO
3178
3179         # Normally we would collect these definitions in the config.h,
3180         # but (like _XOPEN_SOURCE), some environments rely on having these
3181         # defined before any of the system headers are included.  Another
3182         # case comes up with C++, e.g., on AIX the compiler compiles the
3183         # header files by themselves before looking at the body files it is
3184         # told to compile.  For ncurses, those header files do not include
3185         # the config.h
3186         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
3187         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
3188         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
3189
3190         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3191                 AC_TRY_COMPILE([
3192 #include <sys/types.h>
3193 #include <dirent.h>
3194                 ],[
3195                 /* if transitional largefile support is setup, this is true */
3196                 extern struct dirent64 * readdir(DIR *);
3197                 struct dirent64 *x = readdir((DIR *)0);
3198                 struct dirent *y = readdir((DIR *)0);
3199                 int z = x - y;
3200                 ],
3201                 [cf_cv_struct_dirent64=yes],
3202                 [cf_cv_struct_dirent64=no])
3203         ])
3204         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3205         fi
3206 ])
3207 ])
3208 dnl ---------------------------------------------------------------------------
3209 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3210 dnl -----------------
3211 dnl Check for compiler/linker flags used to temporarily force usage of static
3212 dnl libraries.  This depends on the compiler and platform.  Use this to help
3213 dnl ensure that the linker picks up a given library based on its position in
3214 dnl the list of linker options and libraries.
3215 AC_DEFUN([CF_LDFLAGS_STATIC],[
3216
3217 if test "$GCC" = yes ; then
3218         case $cf_cv_system_name in
3219         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3220                 LDFLAGS_STATIC=
3221                 LDFLAGS_SHARED=
3222                 ;;
3223         (*)     # normally, except when broken
3224                 LDFLAGS_STATIC=-static
3225                 LDFLAGS_SHARED=-dynamic
3226                 ;;
3227         esac
3228 else
3229         case $cf_cv_system_name in
3230         (aix[[4-7]]*)   # from ld manpage
3231                 LDFLAGS_STATIC=-bstatic
3232                 LDFLAGS_SHARED=-bdynamic
3233                 ;;
3234         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3235                 # We could also use just "archive" and "shared".
3236                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3237                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3238                 ;;
3239         (irix*)         # from ld manpage IRIX64
3240                 LDFLAGS_STATIC=-Bstatic
3241                 LDFLAGS_SHARED=-Bdynamic
3242                 ;;
3243         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3244                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3245                 LDFLAGS_STATIC=-noso
3246                 LDFLAGS_SHARED=-so_archive
3247                 ;;
3248         (solaris2*)
3249                 LDFLAGS_STATIC=-Bstatic
3250                 LDFLAGS_SHARED=-Bdynamic
3251                 ;;
3252         esac
3253 fi
3254
3255 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3256 then
3257         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3258
3259         rm -f libconftest.a
3260         cat >conftest.$ac_ext <<EOF
3261 #line __oline__ "configure"
3262 #include <stdio.h>
3263 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3264 EOF
3265         if AC_TRY_EVAL(ac_compile) ; then
3266                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3267                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3268         fi
3269         rm -f conftest.*
3270
3271         cf_save_LIBS="$LIBS"
3272
3273         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3274         AC_TRY_LINK([
3275 #line __oline__ "configure"
3276 #include <stdio.h>
3277 int cf_ldflags_static(FILE *fp);
3278 ],[
3279         return cf_ldflags_static(stdin);
3280 ],[
3281         # some linkers simply ignore the -dynamic
3282         case x`file conftest$ac_exeext 2>/dev/null` in
3283         (*static*)
3284                 cf_ldflags_static=no
3285                 ;;
3286         (*)
3287                 cf_ldflags_static=yes
3288                 ;;
3289         esac
3290 ],[cf_ldflags_static=no])
3291
3292         rm -f libconftest.*
3293         LIBS="$cf_save_LIBS"
3294
3295         AC_MSG_RESULT($cf_ldflags_static)
3296
3297         if test $cf_ldflags_static != yes
3298         then
3299                 LDFLAGS_STATIC=
3300                 LDFLAGS_SHARED=
3301         fi
3302 else
3303         LDFLAGS_STATIC=
3304         LDFLAGS_SHARED=
3305 fi
3306
3307 AC_SUBST(LDFLAGS_STATIC)
3308 AC_SUBST(LDFLAGS_SHARED)
3309 ])
3310 dnl ---------------------------------------------------------------------------
3311 dnl CF_LD_RPATH_OPT version: 7 updated: 2016/02/20 18:01:19
3312 dnl ---------------
3313 dnl For the given system and compiler, find the compiler flags to pass to the
3314 dnl loader to use the "rpath" feature.
3315 AC_DEFUN([CF_LD_RPATH_OPT],
3316 [
3317 AC_REQUIRE([CF_CHECK_CACHE])
3318
3319 LD_RPATH_OPT=
3320 AC_MSG_CHECKING(for an rpath option)
3321 case $cf_cv_system_name in
3322 (irix*)
3323         if test "$GCC" = yes; then
3324                 LD_RPATH_OPT="-Wl,-rpath,"
3325         else
3326                 LD_RPATH_OPT="-rpath "
3327         fi
3328         ;;
3329 (linux*|gnu*|k*bsd*-gnu|freebsd*)
3330         LD_RPATH_OPT="-Wl,-rpath,"
3331         ;;
3332 (openbsd[[2-9]].*|mirbsd*)
3333         LD_RPATH_OPT="-Wl,-rpath,"
3334         ;;
3335 (dragonfly*)
3336         LD_RPATH_OPT="-rpath "
3337         ;;
3338 (netbsd*)
3339         LD_RPATH_OPT="-Wl,-rpath,"
3340         ;;
3341 (osf*|mls+*)
3342         LD_RPATH_OPT="-rpath "
3343         ;;
3344 (solaris2*)
3345         LD_RPATH_OPT="-R"
3346         ;;
3347 (*)
3348         ;;
3349 esac
3350 AC_MSG_RESULT($LD_RPATH_OPT)
3351
3352 case "x$LD_RPATH_OPT" in
3353 (x-R*)
3354         AC_MSG_CHECKING(if we need a space after rpath option)
3355         cf_save_LIBS="$LIBS"
3356         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3357         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3358         LIBS="$cf_save_LIBS"
3359         AC_MSG_RESULT($cf_rpath_space)
3360         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3361         ;;
3362 esac
3363 ])dnl
3364 dnl ---------------------------------------------------------------------------
3365 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
3366 dnl ---------------
3367 dnl Construct a search-list of directories for a nonstandard library-file
3368 dnl
3369 dnl Parameters
3370 dnl     $1 = the variable to return as result
3371 dnl     $2 = the package name
3372 AC_DEFUN([CF_LIBRARY_PATH],
3373 [
3374 $1=
3375 cf_library_path_list=""
3376 if test -n "${LDFLAGS}${LIBS}" ; then
3377         for cf_library_path in $LDFLAGS $LIBS
3378         do
3379                 case $cf_library_path in
3380                 (-L*)
3381                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3382                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3383                         cf_library_path_list="$cf_library_path_list [$]$1"
3384                         ;;
3385                 esac
3386         done
3387 fi
3388
3389 CF_SUBDIR_PATH($1,$2,lib)
3390
3391 $1="$cf_library_path_list [$]$1"
3392 ])dnl
3393 dnl ---------------------------------------------------------------------------
3394 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3395 dnl ------------------
3396 AC_DEFUN([CF_LIBTOOL_VERSION],[
3397 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3398 then
3399         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3400 else
3401         cf_cv_libtool_version=
3402 fi
3403 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3404 ])dnl
3405 dnl ---------------------------------------------------------------------------
3406 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
3407 dnl -------------
3408 dnl Compute the library-prefix for the given host system
3409 dnl $1 = variable to set
3410 define([CF_LIB_PREFIX],
3411 [
3412         case $cf_cv_system_name in
3413         (OS/2*|os2*)
3414                 if test "$DFT_LWR_MODEL" = libtool; then
3415                         LIB_PREFIX='lib'
3416                 else
3417                         LIB_PREFIX=''
3418                 fi
3419                 ;;
3420         (*)     LIB_PREFIX='lib'
3421                 ;;
3422         esac
3423 ifelse($1,,,[$1=$LIB_PREFIX])
3424         AC_SUBST(LIB_PREFIX)
3425 ])dnl
3426 dnl ---------------------------------------------------------------------------
3427 dnl CF_LIB_RULES version: 86 updated: 2015/11/07 20:01:34
3428 dnl ------------
3429 dnl Append definitions and rules for the given models to the subdirectory
3430 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3431 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3432 dnl the corresponding makefile to list the models that we'll generate.
3433 dnl
3434 dnl For shared libraries, make a list of symbolic links to construct when
3435 dnl generating each library.  The convention used for Linux is the simplest
3436 dnl one:
3437 dnl     lib<name>.so    ->
3438 dnl     lib<name>.so.<major>    ->
3439 dnl     lib<name>.so.<maj>.<minor>
3440 dnl
3441 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3442 AC_DEFUN([CF_LIB_RULES],
3443 [
3444 cf_prefix=$LIB_PREFIX
3445 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3446
3447 case $cf_cv_shlib_version in
3448 (cygdll|msysdll|mingw)
3449         TINFO_NAME=$TINFO_ARG_SUFFIX
3450         TINFO_SUFFIX=.dll
3451         ;;
3452 esac
3453
3454 if test -n "$TINFO_SUFFIX" ; then
3455         case $TINFO_SUFFIX in
3456         (tw*)
3457                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
3458                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
3459                 ;;
3460         (t*)
3461                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
3462                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
3463                 ;;
3464         (w*)
3465                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
3466                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
3467                 ;;
3468         esac
3469 fi
3470
3471 for cf_dir in $SRC_SUBDIRS
3472 do
3473         if test ! -d $srcdir/$cf_dir ; then
3474                 continue
3475         elif test -f $srcdir/$cf_dir/modules; then
3476
3477                 SHARED_LIB=
3478                 Libs_To_Make=
3479                 cf_awk_program=
3480                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
3481                 then
3482                         cf_awk_program="$cf_awk_program\
3483 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
3484 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
3485 "
3486                 fi
3487
3488                 if test "x$WILDCARD_SYMS" = xno
3489                 then
3490                         cf_awk_program="$cf_awk_program\
3491 /[[     ]]_\\*;/ { skip=1; next; }\
3492 "
3493                 fi
3494
3495                 if test "x$cf_awk_program" != "x"
3496                 then
3497                         cat >>$cf_dir/Makefile <<CF_EOF
3498
3499 # Generated by CF_LIB_RULES
3500 resulting.map: $UNALTERED_SYMS
3501         $AWK 'BEGIN { skip = 1; last=""; } \
3502 $cf_awk_program \
3503 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
3504  skip = 0; last = \[$]\[$]0; } \
3505 END { print last; }' < $UNALTERED_SYMS >\[$]@
3506
3507 distclean::
3508         rm -f resulting.map
3509 CF_EOF
3510                 fi
3511
3512                 for cf_item in $cf_LIST_MODELS
3513                 do
3514                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3515                         cf_libname=$cf_dir
3516                         test "$cf_dir" = c++ && cf_libname=ncurses++
3517                         if test $cf_item = shared ; then
3518                                 if test -n "${LIB_SUFFIX}"
3519                                 then
3520                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3521                                 else
3522                                         cf_shared_suffix="$cf_suffix"
3523                                 fi
3524                                 if test "$cf_cv_do_symlinks" = yes ; then
3525                                         cf_version_name=
3526
3527                                         case "$cf_cv_shlib_version" in
3528                                         (rel)
3529                                                 cf_version_name=REL_VERSION
3530                                                 ;;
3531                                         (abi)
3532                                                 cf_version_name=ABI_VERSION
3533                                                 ;;
3534                                         esac
3535
3536                                         if test -n "$cf_version_name"
3537                                         then
3538                                                 case "$cf_cv_system_name" in
3539                                                 (darwin*)
3540                                                         # "w", etc?
3541                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3542                                                         ;;
3543                                                 (*)
3544                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3545                                                         ;;
3546                                                 esac
3547                                         fi
3548                                         if test -n "${USE_LIB_SUFFIX}"
3549                                         then
3550                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3551                                         else
3552                                                 cf_shared_suffix="$cf_suffix"
3553                                         fi
3554                                 fi
3555                                 # cygwin needs import library, and has unique naming convention
3556                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3557                                 # use 'cyg' prefix for shared lib.
3558                                 case $cf_cv_shlib_version in
3559                                 (cygdll)
3560                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3561                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
3562                                         ;;
3563                                 (msysdll)
3564                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3565                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
3566                                         ;;
3567                                 (mingw)
3568                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3569                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
3570                                         ;;
3571                                 (*)
3572                                         cf_add_lib=
3573                                         ;;
3574                                 esac
3575                                 if test -n "$cf_add_lib"
3576                                 then
3577                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3578                                         continue
3579                                 fi
3580                         fi
3581                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3582                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3583                 done
3584
3585                 if test $cf_dir = ncurses ; then
3586                         cf_subsets="$LIB_SUBSETS"
3587                         cf_r_parts="$cf_subsets"
3588                         cf_liblist="$Libs_To_Make"
3589
3590                         while test -n "$cf_r_parts"
3591                         do
3592                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3593                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3594                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3595                                         cf_add_lib=
3596                                         case $cf_l_parts in
3597                                         (*termlib*)
3598                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3599                                                 ;;
3600                                         (*ticlib*)
3601                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3602                                                 ;;
3603                                         (*)
3604                                                 break
3605                                                 ;;
3606                                         esac
3607                                         if test -n "$cf_add_lib"; then
3608                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
3609                                         fi
3610                                 else
3611                                         break
3612                                 fi
3613                         done
3614                 else
3615                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3616                 fi
3617
3618                 if test $cf_dir = c++; then
3619                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3620                                 cf_list=
3621                                 for cf_item in $Libs_To_Make
3622                                 do
3623                                         case $cf_item in
3624                                         (*.a)
3625                                                 ;;
3626                                         (*)
3627                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3628                                                 ;;
3629                                         esac
3630                                         for cf_test in $cf_list
3631                                         do
3632                                                 if test "$cf_test" = "$cf_item"
3633                                                 then
3634                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3635                                                         cf_item=
3636                                                         break
3637                                                 fi
3638                                         done
3639                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3640                                 done
3641                                 Libs_To_Make="$cf_list"
3642                         fi
3643                 fi
3644
3645                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3646                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3647                         $cf_dir/Makefile >$cf_dir/Makefile.out
3648                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3649
3650                 $AWK -f $srcdir/mk-0th.awk \
3651                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3652                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3653
3654                 for cf_subset in $cf_subsets
3655                 do
3656                         cf_subdirs=
3657                         for cf_item in $cf_LIST_MODELS
3658                         do
3659
3660                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3661                         CF_UPPER(cf_ITEM,$cf_item)
3662
3663                         CXX_MODEL=$cf_ITEM
3664                         if test "$CXX_MODEL" = SHARED; then
3665                                 case $cf_cv_shlib_version in
3666                                 (cygdll|msysdll|mingw)
3667                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3668                                         with_shared_cxx=yes
3669                                         ;;
3670                                 (*)
3671                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3672                                         ;;
3673                                 esac
3674                         fi
3675
3676                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3677                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3678
3679                         # Test for case where we build libtinfo with a different name.
3680                         cf_libname=$cf_dir
3681                         if test $cf_dir = ncurses ; then
3682                                 case $cf_subset in
3683                                 (*base*)
3684                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
3685                                         ;;
3686                                 (*termlib*)
3687                                         cf_libname=$TINFO_LIB_SUFFIX
3688                                         ;;
3689                                 (ticlib*)
3690                                         cf_libname=$TICS_LIB_SUFFIX
3691                                         ;;
3692                                 esac
3693                         elif test $cf_dir = c++ ; then
3694                                 cf_libname=ncurses++$USE_LIB_SUFFIX
3695                         else
3696                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
3697                         fi
3698                         if test -n "${USE_ARG_SUFFIX}" ; then
3699                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
3700                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${USE_LIB_SUFFIX}%%"`
3701                         fi
3702
3703                         # These dependencies really are for development, not
3704                         # builds, but they are useful in porting, too.
3705                         cf_depend="../include/ncurses_cfg.h"
3706                         if test "$srcdir" = "."; then
3707                                 cf_reldir="."
3708                         else
3709                                 cf_reldir="\${srcdir}"
3710                         fi
3711
3712                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3713                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3714                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3715                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3716                         fi
3717
3718                         cf_dir_suffix=
3719                         old_cf_suffix="$cf_suffix"
3720                         if test "$cf_cv_shlib_version_infix" = yes ; then
3721                         if test -n "$USE_LIB_SUFFIX" ; then
3722                                 case $USE_LIB_SUFFIX in
3723                                 (tw*)
3724                                         cf_libname=`echo $cf_libname | sed 's/tw'$EXTRA_SUFFIX'$//'`
3725                                         cf_suffix=`echo $cf_suffix | sed 's/^tw'$EXTRA_SUFFIX'//'`
3726                                         cf_dir_suffix=tw$EXTRA_SUFFIX
3727                                         ;;
3728                                 (t*)
3729                                         cf_libname=`echo $cf_libname | sed 's/t'$EXTRA_SUFFIX'$//'`
3730                                         cf_suffix=`echo $cf_suffix | sed 's/^t'$EXTRA_SUFFIX'//'`
3731                                         cf_dir_suffix=t$EXTRA_SUFFIX
3732                                         ;;
3733                                 (w*)
3734                                         cf_libname=`echo $cf_libname | sed 's/w'$EXTRA_SUFFIX'$//'`
3735                                         cf_suffix=`echo $cf_suffix | sed 's/^w'$EXTRA_SUFFIX'//'`
3736                                         cf_dir_suffix=w$EXTRA_SUFFIX
3737                                         ;;
3738                                 (*)
3739                                         cf_libname=`echo $cf_libname | sed 's/'$EXTRA_SUFFIX'$//'`
3740                                         cf_suffix=`echo $cf_suffix | sed 's/^'$EXTRA_SUFFIX'//'`
3741                                         cf_dir_suffix=$EXTRA_SUFFIX
3742                                         ;;
3743                                 esac
3744                         fi
3745                         fi
3746
3747                         $AWK -f $srcdir/mk-1st.awk \
3748                                 name=${cf_libname}${cf_dir_suffix} \
3749                                 traces=$LIB_TRACING \
3750                                 MODEL=$cf_ITEM \
3751                                 CXX_MODEL=$CXX_MODEL \
3752                                 model=$cf_subdir \
3753                                 prefix=$cf_prefix \
3754                                 suffix=$cf_suffix \
3755                                 subset=$cf_subset \
3756                                 driver=$cf_cv_term_driver \
3757                                 SymLink="$LN_S" \
3758                                 TermlibRoot=$TINFO_NAME \
3759                                 TermlibSuffix=$TINFO_SUFFIX \
3760                                 ShlibVer=$cf_cv_shlib_version \
3761                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3762                                 ReLink=${cf_cv_do_relink:-no} \
3763                                 DoLinks=$cf_cv_do_symlinks \
3764                                 rmSoLocs=$cf_cv_rm_so_locs \
3765                                 ldconfig="$LDCONFIG" \
3766                                 overwrite=$WITH_OVERWRITE \
3767                                 depend="$cf_depend" \
3768                                 host="$host" \
3769                                 libtool_version="$LIBTOOL_VERSION" \
3770                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3771
3772                         cf_suffix="$old_cf_suffix"
3773
3774                         for cf_subdir2 in $cf_subdirs lib
3775                         do
3776                                 test $cf_subdir = $cf_subdir2 && break
3777                         done
3778                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3779                         $AWK -f $srcdir/mk-2nd.awk \
3780                                 name=$cf_dir \
3781                                 traces=$LIB_TRACING \
3782                                 MODEL=$cf_ITEM \
3783                                 model=$cf_subdir \
3784                                 subset=$cf_subset \
3785                                 srcdir=$srcdir \
3786                                 echo=$WITH_ECHO \
3787                                 crenames=$cf_cv_prog_CC_c_o \
3788                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3789                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3790                         cf_subdirs="$cf_subdirs $cf_subdir"
3791                         done
3792                 done
3793         fi
3794
3795         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
3796 done
3797
3798 for cf_dir in $SRC_SUBDIRS
3799 do
3800         if test ! -d $srcdir/$cf_dir ; then
3801                 continue
3802         fi
3803
3804         if test -f $cf_dir/Makefile ; then
3805                 case "$cf_dir" in
3806                 (Ada95)
3807                         echo 'libs \' >> Makefile
3808                         echo 'install.libs \' >> Makefile
3809                         echo 'uninstall.libs ::' >> Makefile
3810                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
3811                         ;;
3812                 esac
3813         fi
3814
3815         if test -f $srcdir/$cf_dir/modules; then
3816                 echo >> Makefile
3817                 if test -f $srcdir/$cf_dir/headers; then
3818 cat >> Makefile <<CF_EOF
3819 install.includes \\
3820 uninstall.includes \\
3821 CF_EOF
3822                 fi
3823 if test "$cf_dir" != "c++" ; then
3824 echo 'lint \' >> Makefile
3825 fi
3826 cat >> Makefile <<CF_EOF
3827 libs \\
3828 lintlib \\
3829 install.libs \\
3830 uninstall.libs \\
3831 install.$cf_dir \\
3832 uninstall.$cf_dir ::
3833         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3834 CF_EOF
3835         elif test -f $srcdir/$cf_dir/headers; then
3836 cat >> Makefile <<CF_EOF
3837
3838 libs \\
3839 install.libs \\
3840 uninstall.libs \\
3841 install.includes \\
3842 uninstall.includes ::
3843         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3844 CF_EOF
3845 fi
3846 done
3847
3848 if test "x$cf_with_db_install" = xyes; then
3849 cat >> Makefile <<CF_EOF
3850
3851 install.libs uninstall.libs \\
3852 install.data uninstall.data ::
3853 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3854 CF_EOF
3855 else
3856 cat >> Makefile <<CF_EOF
3857
3858 install.libs uninstall.libs ::
3859         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3860 CF_EOF
3861 fi
3862
3863 if test "x$cf_with_manpages" = xyes; then
3864 cat >> Makefile <<CF_EOF
3865
3866 install.man \\
3867 uninstall.man ::
3868         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
3869 CF_EOF
3870 fi
3871
3872 cat >> Makefile <<CF_EOF
3873
3874 distclean ::
3875         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3876         rm -f headers.sh headers.sed mk_shared_lib.sh
3877         rm -f edit_man.* man_alias.*
3878         rm -rf \${DIRS_TO_MAKE}
3879 CF_EOF
3880
3881 # Special case: tack's manpage lives in its own directory.
3882 if test "x$cf_with_manpages" = xyes; then
3883 if test -d tack ; then
3884 if test -f $srcdir/$tack.h; then
3885 cat >> Makefile <<CF_EOF
3886
3887 install.man \\
3888 uninstall.man ::
3889         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
3890 CF_EOF
3891 fi
3892 fi
3893 fi
3894
3895 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3896 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3897 dnl anything, and will make it more standardized.  It's awkward to decide this
3898 dnl at configuration because of quoting, so we'll simply make all headers
3899 dnl installed via a script that can do the right thing.
3900
3901 rm -f headers.sed headers.sh
3902
3903 dnl ( generating this script makes the makefiles a little tidier :-)
3904 echo creating headers.sh
3905 cat >headers.sh <<CF_EOF
3906 #! $SHELL
3907 # This shell script is generated by the 'configure' script.  It is invoked in a
3908 # subdirectory of the build tree.  It generates a sed-script in the parent
3909 # directory that is used to adjust includes for header files that reside in a
3910 # subdirectory of /usr/include, etc.
3911 PRG=""
3912 while test \[$]# != 3
3913 do
3914 PRG="\$PRG \[$]1"; shift
3915 done
3916 DST=\[$]1
3917 REF=\[$]2
3918 SRC=\[$]3
3919 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3920 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3921 echo installing \$SRC in \$DST
3922 CF_EOF
3923
3924 if test $WITH_CURSES_H = yes; then
3925         cat >>headers.sh <<CF_EOF
3926 case \$DST in
3927 (/*/include/*)
3928         END=\`basename \$DST\`
3929         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3930         do
3931                 NAME=\`basename \$i\`
3932                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3933         done
3934         ;;
3935 (*)
3936         echo "" >> \$TMPSED
3937         ;;
3938 esac
3939 CF_EOF
3940
3941 else
3942         cat >>headers.sh <<CF_EOF
3943 case \$DST in
3944 (/*/include/*)
3945         END=\`basename \$DST\`
3946         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3947         do
3948                 NAME=\`basename \$i\`
3949                 if test "\$NAME" = "curses.h"
3950                 then
3951                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3952                         NAME=ncurses.h
3953                 fi
3954                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3955         done
3956         ;;
3957 (*)
3958         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3959         ;;
3960 esac
3961 CF_EOF
3962 fi
3963 cat >>headers.sh <<CF_EOF
3964 rm -f \$TMPSRC
3965 sed -f \$TMPSED \$SRC > \$TMPSRC
3966 NAME=\`basename \$SRC\`
3967 CF_EOF
3968 if test $WITH_CURSES_H != yes; then
3969         cat >>headers.sh <<CF_EOF
3970 test "\$NAME" = "curses.h" && NAME=ncurses.h
3971 CF_EOF
3972 fi
3973 cat >>headers.sh <<CF_EOF
3974 # Just in case someone gzip'd manpages, remove the conflicting copy.
3975 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3976
3977 eval \$PRG \$TMPSRC \$DST/\$NAME
3978 rm -f \$TMPSRC \$TMPSED
3979 CF_EOF
3980
3981 chmod 0755 headers.sh
3982
3983 for cf_dir in $SRC_SUBDIRS
3984 do
3985         if test ! -d $srcdir/$cf_dir ; then
3986                 continue
3987         fi
3988
3989         if test -f $srcdir/$cf_dir/headers; then
3990                 $AWK -f $srcdir/mk-hdr.awk \
3991                         subset="$LIB_SUBSETS" \
3992                         compat="$WITH_CURSES_H" \
3993                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3994         fi
3995
3996         if test -f $srcdir/$cf_dir/modules; then
3997                 if test "$cf_dir" != "c++" ; then
3998                         cat >>$cf_dir/Makefile <<"CF_EOF"
3999 depend : ${AUTO_SRC}
4000         makedepend -- ${CPPFLAGS} -- ${C_SRC}
4001
4002 # DO NOT DELETE THIS LINE -- make depend depends on it.
4003 CF_EOF
4004                 fi
4005         fi
4006 done
4007 AC_SUBST(Libs_To_Make)
4008 ])dnl
4009 dnl ---------------------------------------------------------------------------
4010 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
4011 dnl -------------
4012 dnl Find the and soname for the given shared library.  Set the cache variable
4013 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
4014 dnl variable to "unknown".
4015 dnl
4016 dnl $1 = headers
4017 dnl $2 = code
4018 dnl $3 = library name
4019 AC_DEFUN([CF_LIB_SONAME],
4020 [
4021 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
4022
4023 cf_cv_$3_soname=unknown
4024 if test "$cross_compiling" != yes ; then
4025 cat >conftest.$ac_ext <<CF_EOF
4026 $1
4027 int main()
4028 {
4029 $2
4030         ${cf_cv_main_return:-return}(0);
4031 }
4032 CF_EOF
4033 cf_save_LIBS="$LIBS"
4034         CF_ADD_LIB($3)
4035         if AC_TRY_EVAL(ac_compile) ; then
4036                 if AC_TRY_EVAL(ac_link) ; then
4037                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
4038                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
4039                 fi
4040         fi
4041 rm -rf conftest*
4042 LIBS="$cf_save_LIBS"
4043 fi
4044 ])
4045 ])
4046 dnl ---------------------------------------------------------------------------
4047 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
4048 dnl -------------
4049 dnl Compute the library file-suffix from the given model name
4050 dnl $1 = model name
4051 dnl $2 = variable to set (the nominal library suffix)
4052 dnl $3 = dependency variable to set (actual filename)
4053 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4054 AC_DEFUN([CF_LIB_SUFFIX],
4055 [
4056         case X$1 in
4057         (Xlibtool)
4058                 $2='.la'
4059                 $3=[$]$2
4060                 ;;
4061         (Xdebug)
4062                 $2='_g.a'
4063                 $3=[$]$2
4064                 ;;
4065         (Xprofile)
4066                 $2='_p.a'
4067                 $3=[$]$2
4068                 ;;
4069         (Xshared)
4070                 case $cf_cv_system_name in
4071                 (aix[[5-7]]*)
4072                         $2='.so'
4073                         $3=[$]$2
4074                         ;;
4075                 (cygwin*|msys*|mingw*)
4076                         $2='.dll'
4077                         $3='.dll.a'
4078                         ;;
4079                 (darwin*)
4080                         $2='.dylib'
4081                         $3=[$]$2
4082                         ;;
4083                 (hpux*)
4084                         case $target in
4085                         (ia64*)
4086                                 $2='.so'
4087                                 $3=[$]$2
4088                                 ;;
4089                         (*)
4090                                 $2='.sl'
4091                                 $3=[$]$2
4092                                 ;;
4093                         esac
4094                         ;;
4095                 (*)
4096                         $2='.so'
4097                         $3=[$]$2
4098                         ;;
4099                 esac
4100                 ;;
4101         (*)
4102                 $2='.a'
4103                 $3=[$]$2
4104                 ;;
4105         esac
4106         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
4107         then
4108                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
4109                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
4110         fi
4111 ])dnl
4112 dnl ---------------------------------------------------------------------------
4113 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
4114 dnl -----------
4115 dnl Compute the string to append to -library from the given model name
4116 dnl $1 = model name
4117 dnl $2 = variable to set
4118 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4119 AC_DEFUN([CF_LIB_TYPE],
4120 [
4121         case $1 in
4122         (libtool) $2=''   ;;
4123         (normal)  $2=''   ;;
4124         (debug)   $2='_g' ;;
4125         (profile) $2='_p' ;;
4126         (shared)  $2=''   ;;
4127         esac
4128         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
4129 ])dnl
4130 dnl ---------------------------------------------------------------------------
4131 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
4132 dnl ----------------
4133 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
4134 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
4135 dnl have to provide wrappers for global tables to ensure they're linked
4136 dnl properly.
4137 AC_DEFUN([CF_LINK_DATAONLY],
4138 [
4139 AC_MSG_CHECKING([if data-only library module links])
4140 AC_CACHE_VAL(cf_cv_link_dataonly,[
4141         rm -f conftest.a
4142         cat >conftest.$ac_ext <<EOF
4143 #line __oline__ "configure"
4144 int     testdata[[3]] = { 123, 456, 789 };
4145 EOF
4146         if AC_TRY_EVAL(ac_compile) ; then
4147                 mv conftest.o data.o && \
4148                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
4149         fi
4150         rm -f conftest.$ac_ext data.o
4151         cat >conftest.$ac_ext <<EOF
4152 #line __oline__ "configure"
4153 int     testfunc()
4154 {
4155 #if defined(NeXT)
4156         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
4157 #else
4158         extern int testdata[[3]];
4159         return testdata[[0]] == 123
4160            &&  testdata[[1]] == 456
4161            &&  testdata[[2]] == 789;
4162 #endif
4163 }
4164 EOF
4165         if AC_TRY_EVAL(ac_compile); then
4166                 mv conftest.o func.o && \
4167                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
4168         fi
4169         rm -f conftest.$ac_ext func.o
4170         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
4171         cf_saveLIBS="$LIBS"
4172         LIBS="conftest.a $LIBS"
4173         AC_TRY_RUN([
4174         int main()
4175         {
4176                 extern int testfunc();
4177                 ${cf_cv_main_return:-return} (!testfunc());
4178         }
4179         ],
4180         [cf_cv_link_dataonly=yes],
4181         [cf_cv_link_dataonly=no],
4182         [cf_cv_link_dataonly=unknown])
4183         LIBS="$cf_saveLIBS"
4184         ])
4185 AC_MSG_RESULT($cf_cv_link_dataonly)
4186
4187 if test "$cf_cv_link_dataonly" = no ; then
4188         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
4189         BROKEN_LINKER=1
4190 fi
4191
4192 ])dnl
4193 dnl ---------------------------------------------------------------------------
4194 dnl CF_LINK_FUNCS version: 8 updated: 2012/10/06 17:56:13
4195 dnl -------------
4196 dnl Most Unix systems have both link and symlink, a few don't have symlink.
4197 dnl A few non-Unix systems implement symlink, but not link.
4198 dnl A few non-systems implement neither (or have nonfunctional versions).
4199 AC_DEFUN([CF_LINK_FUNCS],
4200 [
4201 AC_CHECK_FUNCS( \
4202         remove \
4203         unlink )
4204
4205 if test "$cross_compiling" = yes ; then
4206         AC_CHECK_FUNCS( \
4207                 link \
4208                 symlink )
4209 else
4210         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
4211                 cf_cv_link_funcs=
4212                 for cf_func in link symlink ; do
4213                         AC_TRY_RUN([
4214 #include <sys/types.h>
4215 #include <sys/stat.h>
4216 #ifdef HAVE_UNISTD_H
4217 #include <unistd.h>
4218 #endif
4219 int main()
4220 {
4221         int fail = 0;
4222         char *src = "config.log";
4223         char *dst = "conftest.chk";
4224         struct stat src_sb;
4225         struct stat dst_sb;
4226
4227         stat(src, &src_sb);
4228         fail = ($cf_func("config.log", "conftest.chk") < 0)
4229             || (stat(dst, &dst_sb) < 0)
4230             || (dst_sb.st_mtime != src_sb.st_mtime);
4231 #ifdef HAVE_UNLINK
4232         unlink(dst);
4233 #else
4234         remove(dst);
4235 #endif
4236         ${cf_cv_main_return:-return} (fail);
4237 }
4238                         ],[
4239                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
4240                         eval 'ac_cv_func_'$cf_func'=yes'],[
4241                         eval 'ac_cv_func_'$cf_func'=no'],[
4242                         eval 'ac_cv_func_'$cf_func'=error'])
4243                 done
4244                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
4245         ])
4246         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
4247         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
4248 fi
4249 ])dnl
4250 dnl ---------------------------------------------------------------------------
4251 dnl CF_MAKEFLAGS version: 17 updated: 2015/08/05 20:44:28
4252 dnl ------------
4253 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
4254 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
4255 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
4256 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
4257 AC_DEFUN([CF_MAKEFLAGS],
4258 [
4259 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
4260         cf_cv_makeflags=''
4261         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
4262         do
4263                 cat >cf_makeflags.tmp <<CF_EOF
4264 SHELL = $SHELL
4265 all :
4266         @ echo '.$cf_option'
4267 CF_EOF
4268                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
4269                 case "$cf_result" in
4270                 (.*k|.*kw)
4271                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
4272                         case "$cf_result" in
4273                         (.*CC=*)        cf_cv_makeflags=
4274                                 ;;
4275                         (*)     cf_cv_makeflags=$cf_option
4276                                 ;;
4277                         esac
4278                         break
4279                         ;;
4280                 (.-)    ;;
4281                 (*)     echo "given option \"$cf_option\", no match \"$cf_result\""
4282                         ;;
4283                 esac
4284         done
4285         rm -f cf_makeflags.tmp
4286 ])
4287
4288 AC_SUBST(cf_cv_makeflags)
4289 ])dnl
4290 dnl ---------------------------------------------------------------------------
4291 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
4292 dnl ------------
4293 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
4294 dnl a monocase filesystem.
4295 AC_DEFUN([CF_MAKE_TAGS],[
4296 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
4297
4298 AC_CHECK_PROGS(CTAGS, exctags ctags)
4299 AC_CHECK_PROGS(ETAGS, exetags etags)
4300
4301 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
4302
4303 if test "$cf_cv_mixedcase" = yes ; then
4304         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
4305 else
4306         MAKE_UPPER_TAGS=no
4307 fi
4308
4309 if test "$MAKE_UPPER_TAGS" = yes ; then
4310         MAKE_UPPER_TAGS=
4311 else
4312         MAKE_UPPER_TAGS="#"
4313 fi
4314
4315 if test "$MAKE_LOWER_TAGS" = yes ; then
4316         MAKE_LOWER_TAGS=
4317 else
4318         MAKE_LOWER_TAGS="#"
4319 fi
4320
4321 AC_SUBST(CTAGS)
4322 AC_SUBST(ETAGS)
4323
4324 AC_SUBST(MAKE_UPPER_TAGS)
4325 AC_SUBST(MAKE_LOWER_TAGS)
4326 ])dnl
4327 dnl ---------------------------------------------------------------------------
4328 dnl CF_MANPAGE_FORMAT version: 11 updated: 2015/04/18 08:56:57
4329 dnl -----------------
4330 dnl Option to allow user to override automatic configuration of manpage format.
4331 dnl There are several special cases:
4332 dnl
4333 dnl     gzip - man checks for, can display gzip'd files
4334 dnl     compress - man checks for, can display compressed files
4335 dnl     BSDI - files in the cat-directories are suffixed ".0"
4336 dnl     formatted - installer should format (put files in cat-directory)
4337 dnl     catonly - installer should only format, e.g., for a turnkey system.
4338 dnl
4339 dnl There are other configurations which this macro does not test, e.g., HPUX's
4340 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
4341 dnl convention would not match our use).
4342 AC_DEFUN([CF_MANPAGE_FORMAT],
4343 [
4344 AC_REQUIRE([CF_PATHSEP])
4345 AC_MSG_CHECKING(format of man-pages)
4346
4347 AC_ARG_WITH(manpage-format,
4348         [  --with-manpage-format&