aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2021,2022 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: aclocal.m4,v 1.1023 2022/11/05 20:13:19 tom Exp $
  33 dnl Macros used in NCURSES auto-configuration script.
  34 dnl
  35 dnl These macros are maintained separately from NCURSES.  The copyright on
  36 dnl this file applies to the aggregation of macros and does not affect use of
  37 dnl these macros in other applications.
  38 dnl
  39 dnl See these pages for additional information:
  40 dnl             https://invisible-island.net/autoconf/
  41 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  42 dnl
  43 dnl ---------------------------------------------------------------------------
  44 dnl ---------------------------------------------------------------------------
  45 dnl AM_LANGINFO_CODESET version: 6 updated: 2021/01/01 16:53:59
  46 dnl -------------------
  47 dnl Inserted as requested by gettext 0.10.40
  48 dnl File from /usr/share/aclocal
  49 dnl codeset.m4
  50 dnl ====================
  51 dnl serial AM1
  52 dnl
  53 dnl From Bruno Haible.
  54 AC_DEFUN([AM_LANGINFO_CODESET],
  55 [
  56 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  57         [AC_TRY_LINK([#include <langinfo.h>],
  58         [char* cs = nl_langinfo(CODESET); (void)cs],
  59         am_cv_langinfo_codeset=yes,
  60         am_cv_langinfo_codeset=no)
  61         ])
  62         if test "$am_cv_langinfo_codeset" = yes; then
  63                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  64                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  65         fi
  66 ])dnl
  67 dnl ---------------------------------------------------------------------------
  68 dnl CF_ABI_DEFAULTS version: 3 updated: 2022/01/22 19:13:38
  69 dnl ---------------
  70 dnl Provide configure-script defaults for different ncurses ABIs.
  71 AC_DEFUN([CF_ABI_DEFAULTS],[
  72 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  73
  74 # ABI 5 defaults:
  75 cf_dft_ccharw_max=5
  76 cf_dft_chtype=auto
  77 cf_dft_ext_colors=no
  78 cf_dft_ext_const=no
  79 cf_dft_ext_mouse=no
  80 cf_dft_ext_putwin=no
  81 cf_dft_ext_spfuncs=no
  82 cf_dft_filter_syms=no
  83 cf_dft_interop=no
  84 cf_dft_mmask_t=auto
  85 cf_dft_opaque_curses=no
  86 cf_dft_ordinate_type=short
  87 cf_dft_signed_char=no
  88 cf_dft_tparm_arg=long
  89 cf_dft_with_lp64=no
  90
  91 # ABI 6 defaults:
  92 case x$cf_cv_abi_version in
  93 (x[[6789]])
  94         cf_dft_chtype=uint32_t
  95         cf_dft_ext_colors=yes
  96         cf_dft_ext_const=yes
  97         cf_dft_ext_mouse=yes
  98         cf_dft_ext_putwin=yes
  99         cf_dft_ext_spfuncs=yes
 100         cf_dft_filter_syms=yes
 101         cf_dft_interop=yes
 102         cf_dft_mmask_t=uint32_t
 103         cf_dft_tparm_arg=intptr_t
 104         cf_dft_with_lp64=yes
 105         ;;
 106 esac
 107
 108 # ABI 7 defaults:
 109 case x$cf_cv_abi_version in
 110 (x[[789]])
 111         cf_dft_ccharw_max=6
 112         cf_dft_mmask_t=uint64_t
 113         cf_dft_opaque_curses=yes
 114         cf_dft_ordinate_type=int
 115         cf_dft_signed_char=yes
 116         # also: remove the wgetch-events feature in ABI 7
 117         ;;
 118 esac
 119 ])dnl
 120 dnl ---------------------------------------------------------------------------
 121 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 122 dnl ------------------
 123 dnl Conditionally generate script according to whether we're using a given autoconf.
 124 dnl
 125 dnl $1 = version to compare against
 126 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 127 dnl $3 = code to use if AC_ACVERSION is older than $1.
 128 define([CF_ACVERSION_CHECK],
 129 [
 130 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 131 ifdef([m4_version_compare],
 132 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 133 [CF_ACVERSION_COMPARE(
 134 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 135 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 136 dnl ---------------------------------------------------------------------------
 137 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 138 dnl --------------------
 139 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 140 dnl                      MAJOR2, MINOR2, TERNARY2,
 141 dnl                      PRINTABLE2, not FOUND, FOUND)
 142 define([CF_ACVERSION_COMPARE],
 143 [ifelse(builtin([eval], [$2 < $5]), 1,
 144 [ifelse([$8], , ,[$8])],
 145 [ifelse([$9], , ,[$9])])])dnl
 146 dnl ---------------------------------------------------------------------------
 147 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 148 dnl -------------------
 149 dnl Construct the list of include-options for the C programs in the Ada95
 150 dnl binding.
 151 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 152 [
 153 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 154 if test "$srcdir" != "."; then
 155         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 156 fi
 157 if test "$GCC" != yes; then
 158         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 159 elif test "$includedir" != "/usr/include"; then
 160         if test "$includedir" = '${prefix}/include' ; then
 161                 if test x$prefix != x/usr ; then
 162                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 163                 fi
 164         else
 165                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 166         fi
 167 fi
 168 AC_SUBST(ACPPFLAGS)
 169 ])dnl
 170 dnl ---------------------------------------------------------------------------
 171 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 172 dnl ---------------
 173 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 174 AC_DEFUN([CF_ADD_ADAFLAGS],[
 175         ADAFLAGS="$ADAFLAGS $1"
 176         AC_SUBST(ADAFLAGS)
 177 ])dnl
 178 dnl ---------------------------------------------------------------------------
 179 dnl CF_ADD_CFLAGS version: 15 updated: 2020/12/31 10:54:15
 180 dnl -------------
 181 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 182 dnl $1 = flags to add
 183 dnl $2 = if given makes this macro verbose.
 184 dnl
 185 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 186 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 187 dnl confused by the quotes (which require backslashes to keep them usable).
 188 AC_DEFUN([CF_ADD_CFLAGS],
 189 [
 190 cf_fix_cppflags=no
 191 cf_new_cflags=
 192 cf_new_cppflags=
 193 cf_new_extra_cppflags=
 194
 195 for cf_add_cflags in $1
 196 do
 197 case "$cf_fix_cppflags" in
 198 (no)
 199         case "$cf_add_cflags" in
 200         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 201                 case "$cf_add_cflags" in
 202                 (-D*)
 203                         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 204
 205                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 206                                 && test -z "${cf_tst_cflags}" \
 207                                 && cf_fix_cppflags=yes
 208
 209                         if test "$cf_fix_cppflags" = yes ; then
 210                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 211                                 continue
 212                         elif test "${cf_tst_cflags}" = "\"'" ; then
 213                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 214                                 continue
 215                         fi
 216                         ;;
 217                 esac
 218                 case "$CPPFLAGS" in
 219                 (*$cf_add_cflags)
 220                         ;;
 221                 (*)
 222                         case "$cf_add_cflags" in
 223                         (-D*)
 224                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 225                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 226                                 ;;
 227                         esac
 228                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 229                         ;;
 230                 esac
 231                 ;;
 232         (*)
 233                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 234                 ;;
 235         esac
 236         ;;
 237 (yes)
 238         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 239
 240         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^[[^"]]*"'\''//'`
 241
 242         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 243                 && test -z "${cf_tst_cflags}" \
 244                 && cf_fix_cppflags=no
 245         ;;
 246 esac
 247 done
 248
 249 if test -n "$cf_new_cflags" ; then
 250         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 251         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 252 fi
 253
 254 if test -n "$cf_new_cppflags" ; then
 255         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 256         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 257 fi
 258
 259 if test -n "$cf_new_extra_cppflags" ; then
 260         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 261         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 262 fi
 263
 264 AC_SUBST(EXTRA_CPPFLAGS)
 265
 266 ])dnl
 267 dnl ---------------------------------------------------------------------------
 268 dnl CF_ADD_CXXFLAGS version: 1 updated: 2020/04/04 16:16:13
 269 dnl ---------------
 270 dnl Copy non-preprocessor flags to $CXXFLAGS, preprocessor flags to $CPPFLAGS
 271 dnl The second parameter if given makes this macro verbose.
 272 dnl
 273 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 274 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 275 dnl confused by the quotes (which require backslashes to keep them usable).
 276 AC_DEFUN([CF_ADD_CXXFLAGS],
 277 [
 278 cf_save_CXXFLAGS="$CFLAGS"
 279 CFLAGS="$CXXFLAGS"
 280 CF_ADD_CFLAGS($1 ifelse($2,,,[,$2]))
 281 CXXFLAGS="$CFLAGS"
 282 CFLAGS="$cf_save_CXXFLAGS"
 283 ])dnl
 284 dnl ---------------------------------------------------------------------------
 285 dnl CF_ADD_INCDIR version: 17 updated: 2021/09/04 06:35:04
 286 dnl -------------
 287 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it is
 288 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 289 dnl but old versions (and some misinstalled ones) need that.  To make things
 290 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 291 dnl the include-path).
 292 AC_DEFUN([CF_ADD_INCDIR],
 293 [
 294 if test -n "$1" ; then
 295   for cf_add_incdir in $1
 296   do
 297         while test "$cf_add_incdir" != /usr/include
 298         do
 299           if test -d "$cf_add_incdir"
 300           then
 301                 cf_have_incdir=no
 302                 if test -n "$CFLAGS$CPPFLAGS" ; then
 303                   # a loop is needed to ensure we can add subdirs of existing dirs
 304                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 305                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 306                           cf_have_incdir=yes; break
 307                         fi
 308                   done
 309                 fi
 310
 311                 if test "$cf_have_incdir" = no ; then
 312                   if test "$cf_add_incdir" = /usr/local/include ; then
 313                         if test "$GCC" = yes
 314                         then
 315                           cf_save_CPPFLAGS=$CPPFLAGS
 316                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 317                           AC_TRY_COMPILE([#include <stdio.h>],
 318                                   [printf("Hello")],
 319                                   [],
 320                                   [cf_have_incdir=yes])
 321                           CPPFLAGS=$cf_save_CPPFLAGS
 322                         fi
 323                   fi
 324                 fi
 325
 326                 if test "$cf_have_incdir" = no ; then
 327                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 328                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 329
 330                   cf_top_incdir=`echo "$cf_add_incdir" | sed -e 's%/include/.*$%/include%'`
 331                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 332                   cf_add_incdir="$cf_top_incdir"
 333                 else
 334                   break
 335                 fi
 336           else
 337                 break
 338           fi
 339         done
 340   done
 341 fi
 342 ])dnl
 343 dnl ---------------------------------------------------------------------------
 344 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 345 dnl ----------
 346 dnl Add a library, used to enforce consistency.
 347 dnl
 348 dnl $1 = library to add, without the "-l"
 349 dnl $2 = variable to update (default $LIBS)
 350 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 351 dnl ---------------------------------------------------------------------------
 352 dnl CF_ADD_LIBDIR version: 11 updated: 2020/12/31 20:19:42
 353 dnl -------------
 354 dnl     Adds to the library-path
 355 dnl
 356 dnl     Some machines have trouble with multiple -L options.
 357 dnl
 358 dnl $1 is the (list of) directory(s) to add
 359 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 360 dnl
 361 AC_DEFUN([CF_ADD_LIBDIR],
 362 [
 363 if test -n "$1" ; then
 364         for cf_add_libdir in $1
 365         do
 366                 if test "$cf_add_libdir" = /usr/lib ; then
 367                         :
 368                 elif test -d "$cf_add_libdir"
 369                 then
 370                         cf_have_libdir=no
 371                         if test -n "$LDFLAGS$LIBS" ; then
 372                                 # a loop is needed to ensure we can add subdirs of existing dirs
 373                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 374                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 375                                                 cf_have_libdir=yes; break
 376                                         fi
 377                                 done
 378                         fi
 379                         if test "$cf_have_libdir" = no ; then
 380                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 381                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 382                         fi
 383                 fi
 384         done
 385 fi
 386 ])dnl
 387 dnl ---------------------------------------------------------------------------
 388 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
 389 dnl -----------
 390 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 391 dnl prepended to an existing list, since their dependencies are assumed to
 392 dnl already exist in the list.
 393 dnl
 394 dnl $1 = libraries to add, with the "-l", etc.
 395 dnl $2 = variable to update (default $LIBS)
 396 AC_DEFUN([CF_ADD_LIBS],[
 397 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
 398 # reverse order
 399 cf_add_0lib=
 400 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
 401 # filter duplicates
 402 for cf_add_1lib in $cf_add_0lib; do
 403         for cf_add_2lib in $cf_add_libs; do
 404                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
 405                         cf_add_1lib=
 406                         break
 407                 fi
 408         done
 409         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
 410 done
 411 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 412 ])dnl
 413 dnl ---------------------------------------------------------------------------
 414 dnl CF_ADD_SUBDIR_PATH version: 5 updated: 2020/12/31 20:19:42
 415 dnl ------------------
 416 dnl Append to a search-list for a nonstandard header/lib-file
 417 dnl     $1 = the variable to return as result
 418 dnl     $2 = the package name
 419 dnl     $3 = the subdirectory, e.g., bin, include or lib
 420 dnl $4 = the directory under which we will test for subdirectories
 421 dnl $5 = a directory that we do not want $4 to match
 422 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 423 [
 424 test "x$4" != "x$5" && \
 425 test -d "$4" && \
 426 ifelse([$5],NONE,,[{ test -z "$5" || test "x$5" = xNONE || test "x$4" != "x$5"; } &&]) {
 427         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 428         test -d "$4/$3" &&          $1="[$]$1 $4/$3"
 429         test -d "$4/$3/$2" &&       $1="[$]$1 $4/$3/$2"
 430         test -d "$4/$3/$2/$3" &&    $1="[$]$1 $4/$3/$2/$3"
 431         test -d "$4/$2/$3" &&       $1="[$]$1 $4/$2/$3"
 432         test -d "$4/$2/$3/$2" &&    $1="[$]$1 $4/$2/$3/$2"
 433 }
 434 ])dnl
 435 dnl ---------------------------------------------------------------------------
 436 dnl CF_APPEND_CFLAGS version: 3 updated: 2021/09/05 17:25:40
 437 dnl ----------------
 438 dnl Use CF_ADD_CFLAGS after first checking for potential redefinitions.
 439 dnl $1 = flags to add
 440 dnl $2 = if given makes this macro verbose.
 441 define([CF_APPEND_CFLAGS],
 442 [
 443 for cf_add_cflags in $1
 444 do
 445         case "x$cf_add_cflags" in
 446         (x-[[DU]]*)
 447                 CF_REMOVE_CFLAGS($cf_add_cflags,CFLAGS,[$2])
 448                 CF_REMOVE_CFLAGS($cf_add_cflags,CPPFLAGS,[$2])
 449                 ;;
 450         esac
 451         CF_ADD_CFLAGS([$cf_add_cflags],[$2])
 452 done
 453 ])dnl
 454 dnl ---------------------------------------------------------------------------
 455 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 456 dnl --------------
 457 dnl use this macro for appending text without introducing an extra blank at
 458 dnl the beginning
 459 define([CF_APPEND_TEXT],
 460 [
 461         test -n "[$]$1" && $1="[$]$1 "
 462         $1="[$]{$1}$2"
 463 ])dnl
 464 dnl ---------------------------------------------------------------------------
 465 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 466 dnl --------------
 467 dnl Allow user to disable a normally-on option.
 468 AC_DEFUN([CF_ARG_DISABLE],
 469 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 470 dnl ---------------------------------------------------------------------------
 471 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 472 dnl -------------
 473 dnl Allow user to enable a normally-off option.
 474 AC_DEFUN([CF_ARG_ENABLE],
 475 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 476 dnl ---------------------------------------------------------------------------
 477 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 478 dnl -------------
 479 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 480 dnl values.
 481 dnl
 482 dnl Parameters:
 483 dnl $1 = option name
 484 dnl $2 = help-string
 485 dnl $3 = action to perform if option is not default
 486 dnl $4 = action if perform if option is default
 487 dnl $5 = default option value (either 'yes' or 'no')
 488 AC_DEFUN([CF_ARG_OPTION],
 489 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 490         if test "$enableval" != "$5" ; then
 491 ifelse([$3],,[    :]dnl
 492 ,[    $3]) ifelse([$4],,,[
 493         else
 494                 $4])
 495         fi],[enableval=$5 ifelse([$4],,,[
 496         $4
 497 ])dnl
 498 ])])dnl
 499 dnl ---------------------------------------------------------------------------
 500 dnl CF_AR_FLAGS version: 9 updated: 2021/01/01 13:31:04
 501 dnl -----------
 502 dnl Check for suitable "ar" (archiver) options for updating an archive.
 503 dnl
 504 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 505 dnl as well as a workaround for breakage of make's archive rules by the GNU
 506 dnl binutils "ar" program.
 507 AC_DEFUN([CF_AR_FLAGS],[
 508 AC_REQUIRE([CF_PROG_AR])
 509
 510 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 511         case "$cf_cv_system_name" in
 512         (*-msvc*)
 513                 cf_cv_ar_flags=''
 514                 cat >mk_static_lib.sh <<-EOF
 515                 #!$SHELL
 516                 MSVC_BIN="[$]AR"
 517                 out="\[$]1"
 518                 shift
 519                 exec \[$]MSVC_BIN -out:"\[$]out" \[$]@
 520                 EOF
 521                 chmod +x mk_static_lib.sh
 522                 AR=`pwd`/mk_static_lib.sh
 523                 ;;
 524         (*)
 525                 cf_cv_ar_flags=unknown
 526                 for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 527                 do
 528
 529                         # check if $ARFLAGS already contains this choice
 530                         if test "x$ARFLAGS" != "x" ; then
 531                                 cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 532                                 if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 533                                         cf_cv_ar_flags=
 534                                         break
 535                                 fi
 536                         fi
 537
 538                         rm -f "conftest.$ac_cv_objext"
 539                         rm -f conftest.a
 540
 541                         cat >"conftest.$ac_ext" <<EOF
 542 #line __oline__ "configure"
 543 int     testdata[[3]] = { 123, 456, 789 };
 544 EOF
 545                         if AC_TRY_EVAL(ac_compile) ; then
 546                                 echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 547                                 $AR $ARFLAGS "$cf_ar_flags" conftest.a "conftest.$ac_cv_objext" 2>&AC_FD_CC 1>/dev/null
 548                                 if test -f conftest.a ; then
 549                                         cf_cv_ar_flags="$cf_ar_flags"
 550                                         break
 551                                 fi
 552                         else
 553                                 CF_VERBOSE(cannot compile test-program)
 554                                 break
 555                         fi
 556                 done
 557                 rm -f conftest.a "conftest.$ac_ext" "conftest.$ac_cv_objext"
 558                 ;;
 559         esac
 560 ])
 561
 562 if test -n "$ARFLAGS" ; then
 563         if test -n "$cf_cv_ar_flags" ; then
 564                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 565         fi
 566 else
 567         ARFLAGS=$cf_cv_ar_flags
 568 fi
 569
 570 AC_SUBST(ARFLAGS)
 571 ])
 572 dnl ---------------------------------------------------------------------------
 573 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 574 dnl -----------------
 575 dnl Check if awk can handle big strings using printf.  Some older versions of
 576 dnl awk choke on large strings passed via "%s".
 577 dnl
 578 dnl $1 = desired string size
 579 dnl $2 = variable to set with result
 580 AC_DEFUN([CF_AWK_BIG_PRINTF],
 581 [
 582         case x$AWK in
 583         (x)
 584                 eval $2=no
 585                 ;;
 586         (*)
 587                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 588                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 589                         eval $2=yes
 590                 else
 591                         eval $2=no
 592                 fi
 593                 ;;
 594         esac
 595 ])dnl
 596 dnl ---------------------------------------------------------------------------
 597 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 598 dnl ------------
 599 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 600 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 601 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 602 dnl
 603 dnl Treat the configuration-variable specially here, since we're directly
 604 dnl substituting its value (i.e., 1/0).
 605 dnl
 606 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 607 AC_DEFUN([CF_BOOL_DECL],
 608 [
 609 AC_MSG_CHECKING(if we should include stdbool.h)
 610
 611 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 612         AC_TRY_COMPILE([],[bool foo = false],
 613                 [cf_cv_header_stdbool_h=0],
 614                 [AC_TRY_COMPILE([
 615 #ifndef __BEOS__
 616 #include <stdbool.h>
 617 #endif
 618 ],[bool foo = false],
 619                         [cf_cv_header_stdbool_h=1],
 620                         [cf_cv_header_stdbool_h=0])])])
 621
 622 if test "$cf_cv_header_stdbool_h" = 1
 623 then    AC_MSG_RESULT(yes)
 624 else    AC_MSG_RESULT(no)
 625 fi
 626
 627 AC_MSG_CHECKING([for builtin bool type])
 628
 629 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 630         AC_TRY_COMPILE([
 631 #include <stdio.h>
 632 #include <sys/types.h>
 633 ],[bool x = false],
 634                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 635                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 636         ])
 637
 638 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 639 then    AC_MSG_RESULT(yes)
 640 else    AC_MSG_RESULT(no)
 641 fi
 642 ])dnl
 643 dnl ---------------------------------------------------------------------------
 644 dnl CF_BOOL_SIZE version: 18 updated: 2021/09/04 06:35:04
 645 dnl ------------
 646 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 647 dnl Don't bother looking for bool.h, since it has been deprecated.
 648 dnl
 649 dnl If the current compiler is C rather than C++, we get the bool definition
 650 dnl from <stdbool.h>.
 651 AC_DEFUN([CF_BOOL_SIZE],
 652 [
 653 AC_CHECK_SIZEOF(bool,,[
 654 #include <stdlib.h>
 655 #include <stdio.h>
 656
 657 #if defined(__cplusplus)
 658
 659 #ifdef HAVE_GXX_BUILTIN_H
 660 #include <g++/builtin.h>
 661 #elif HAVE_GPP_BUILTIN_H
 662 #include <gpp/builtin.h>
 663 #elif HAVE_BUILTIN_H
 664 #include <builtin.h>
 665 #endif
 666
 667 #else
 668
 669 #if $cf_cv_header_stdbool_h
 670 #include <stdbool.h>
 671 #endif
 672
 673 #endif
 674 ])
 675
 676 AC_CACHE_CHECK(for type of bool, cf_cv_type_of_bool,[
 677         rm -f cf_test.out
 678         AC_TRY_RUN([
 679 #include <stdlib.h>
 680 #include <stdio.h>
 681
 682 #if defined(__cplusplus)
 683
 684 #ifdef HAVE_GXX_BUILTIN_H
 685 #include <g++/builtin.h>
 686 #elif HAVE_GPP_BUILTIN_H
 687 #include <gpp/builtin.h>
 688 #elif HAVE_BUILTIN_H
 689 #include <builtin.h>
 690 #endif
 691
 692 #else
 693
 694 #if $cf_cv_header_stdbool_h
 695 #include <stdbool.h>
 696 #endif
 697
 698 #endif
 699
 700 int main(void)
 701 {
 702         FILE *fp = fopen("cf_test.out", "w");
 703         if (fp != 0) {
 704                 bool x = true;
 705                 if ((bool)(-x) >= 0)
 706                         fputs("unsigned ", fp);
 707                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 708                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 709                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 710                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 711                 fclose(fp);
 712         }
 713         ${cf_cv_main_return:-return}(0);
 714 }
 715                 ],
 716                 [cf_cv_type_of_bool=`cat cf_test.out`
 717                  if test -z "$cf_cv_type_of_bool"; then
 718                    cf_cv_type_of_bool=unknown
 719                  fi],
 720                 [cf_cv_type_of_bool=unknown],
 721                 [
 722                 case x$ac_cv_sizeof_bool in
 723                 (x1) cf_cv_type_of_bool="unsigned char";;
 724                 (x2) cf_cv_type_of_bool="unsigned short";;
 725                 (x4) cf_cv_type_of_bool="unsigned int";;
 726                 (x8) cf_cv_type_of_bool="unsigned long";;
 727                 (*)  cf_cv_type_of_bool=unknown;;
 728                 esac
 729                 ])
 730         rm -f cf_test.out
 731 ])
 732
 733 if test "$cf_cv_type_of_bool" = unknown ; then
 734         case .$NCURSES_BOOL in
 735         (.auto|.) NCURSES_BOOL=unsigned;;
 736         esac
 737         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 738         cf_cv_type_of_bool=$NCURSES_BOOL
 739 fi
 740 ])dnl
 741 dnl ---------------------------------------------------------------------------
 742 dnl CF_BUILD_CC version: 10 updated: 2022/09/24 16:36:41
 743 dnl -----------
 744 dnl If we're cross-compiling, allow the user to override the tools and their
 745 dnl options.  The configure script is oriented toward identifying the host
 746 dnl compiler, etc., but we need a build compiler to generate parts of the
 747 dnl source.
 748 dnl
 749 dnl $1 = default for $CPPFLAGS
 750 dnl $2 = default for $LIBS
 751 AC_DEFUN([CF_BUILD_CC],[
 752 CF_ACVERSION_CHECK(2.52,,
 753         [AC_REQUIRE([CF_PROG_EXT])])
 754 if test "$cross_compiling" = yes ; then
 755
 756         # defaults that we might want to override
 757         : ${BUILD_CFLAGS:=''}
 758         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 759         : ${BUILD_LDFLAGS:=''}
 760         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 761         : ${BUILD_EXEEXT:='$x'}
 762         : ${BUILD_OBJEXT:='o'}
 763
 764         AC_ARG_WITH(build-cc,
 765                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 766                 [BUILD_CC="$withval"],
 767                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 768         AC_MSG_CHECKING(for native build C compiler)
 769         AC_MSG_RESULT($BUILD_CC)
 770
 771         AC_MSG_CHECKING(for native build C preprocessor)
 772         AC_ARG_WITH(build-cpp,
 773                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 774                 [BUILD_CPP="$withval"],
 775                 [BUILD_CPP='${BUILD_CC} -E'])
 776         AC_MSG_RESULT($BUILD_CPP)
 777
 778         AC_MSG_CHECKING(for native build C flags)
 779         AC_ARG_WITH(build-cflags,
 780                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 781                 [BUILD_CFLAGS="$withval"])
 782         AC_MSG_RESULT($BUILD_CFLAGS)
 783
 784         AC_MSG_CHECKING(for native build C preprocessor-flags)
 785         AC_ARG_WITH(build-cppflags,
 786                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 787                 [BUILD_CPPFLAGS="$withval"])
 788         AC_MSG_RESULT($BUILD_CPPFLAGS)
 789
 790         AC_MSG_CHECKING(for native build linker-flags)
 791         AC_ARG_WITH(build-ldflags,
 792                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 793                 [BUILD_LDFLAGS="$withval"])
 794         AC_MSG_RESULT($BUILD_LDFLAGS)
 795
 796         AC_MSG_CHECKING(for native build linker-libraries)
 797         AC_ARG_WITH(build-libs,
 798                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 799                 [BUILD_LIBS="$withval"])
 800         AC_MSG_RESULT($BUILD_LIBS)
 801
 802         # this assumes we're on Unix.
 803         BUILD_EXEEXT=
 804         BUILD_OBJEXT=o
 805
 806         : ${BUILD_CC:='${CC}'}
 807
 808         AC_MSG_CHECKING(if the build-compiler "$BUILD_CC" works)
 809
 810         cf_save_crossed=$cross_compiling
 811         cf_save_ac_link=$ac_link
 812         cross_compiling=no
 813         ac_link='$BUILD_CC -o "conftest$ac_exeext" $BUILD_CFLAGS $BUILD_CPPFLAGS $BUILD_LDFLAGS "conftest.$ac_ext" $BUILD_LIBS >&AS_MESSAGE_LOG_FD'
 814
 815         AC_TRY_RUN([#include <stdio.h>
 816                 int main(int argc, char *argv[])
 817                 {
 818                         ${cf_cv_main_return:-return}(argc < 0 || argv == 0 || argv[0] == 0);
 819                 }
 820         ],
 821                 cf_ok_build_cc=yes,
 822                 cf_ok_build_cc=no,
 823                 cf_ok_build_cc=unknown)
 824
 825         cross_compiling=$cf_save_crossed
 826         ac_link=$cf_save_ac_link
 827
 828         AC_MSG_RESULT($cf_ok_build_cc)
 829
 830         if test "$cf_ok_build_cc" != yes
 831         then
 832                 AC_MSG_ERROR([Cross-build requires two compilers.
 833 Use --with-build-cc to specify the native compiler.])
 834         fi
 835
 836 else
 837         : ${BUILD_CC:='${CC}'}
 838         : ${BUILD_CPP:='${CPP}'}
 839         : ${BUILD_CFLAGS:='${CFLAGS}'}
 840         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 841         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 842         : ${BUILD_LIBS:='${LIBS}'}
 843         : ${BUILD_EXEEXT:='$x'}
 844         : ${BUILD_OBJEXT:='o'}
 845 fi
 846
 847 AC_SUBST(BUILD_CC)
 848 AC_SUBST(BUILD_CPP)
 849 AC_SUBST(BUILD_CFLAGS)
 850 AC_SUBST(BUILD_CPPFLAGS)
 851 AC_SUBST(BUILD_LDFLAGS)
 852 AC_SUBST(BUILD_LIBS)
 853 AC_SUBST(BUILD_EXEEXT)
 854 AC_SUBST(BUILD_OBJEXT)
 855 ])dnl
 856 dnl ---------------------------------------------------------------------------
 857 dnl CF_C11_NORETURN version: 3 updated: 2021/03/28 11:36:23
 858 dnl ---------------
 859 AC_DEFUN([CF_C11_NORETURN],
 860 [
 861 AC_MSG_CHECKING(if you want to use C11 _Noreturn feature)
 862 CF_ARG_ENABLE(stdnoreturn,
 863         [  --enable-stdnoreturn    enable C11 _Noreturn feature for diagnostics],
 864         [enable_stdnoreturn=yes],
 865         [enable_stdnoreturn=no])
 866 AC_MSG_RESULT($enable_stdnoreturn)
 867
 868 if test $enable_stdnoreturn = yes; then
 869 AC_CACHE_CHECK([for C11 _Noreturn feature], cf_cv_c11_noreturn,
 870         [AC_TRY_COMPILE([
 871 #include <stdio.h>
 872 #include <stdlib.h>
 873 #include <stdnoreturn.h>
 874 static _Noreturn void giveup(void) { exit(0); }
 875         ],
 876         [if (feof(stdin)) giveup()],
 877         cf_cv_c11_noreturn=yes,
 878         cf_cv_c11_noreturn=no)
 879         ])
 880 else
 881         cf_cv_c11_noreturn=no,
 882 fi
 883
 884 if test "$cf_cv_c11_noreturn" = yes; then
 885         AC_DEFINE(HAVE_STDNORETURN_H, 1,[Define if <stdnoreturn.h> header is available and working])
 886         AC_DEFINE_UNQUOTED(STDC_NORETURN,_Noreturn,[Define if C11 _Noreturn keyword is supported])
 887         HAVE_STDNORETURN_H=1
 888 else
 889         HAVE_STDNORETURN_H=0
 890 fi
 891
 892 AC_SUBST(HAVE_STDNORETURN_H)
 893 AC_SUBST(STDC_NORETURN)
 894 ])dnl
 895 dnl ---------------------------------------------------------------------------
 896 dnl CF_CC_ENV_FLAGS version: 10 updated: 2020/12/31 18:40:20
 897 dnl ---------------
 898 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 899 dnl into CC.  This will not help with broken scripts that wrap the compiler
 900 dnl with options, but eliminates a more common category of user confusion.
 901 dnl
 902 dnl In particular, it addresses the problem of being able to run the C
 903 dnl preprocessor in a consistent manner.
 904 dnl
 905 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 906 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 907 dnl outweighs that limitation.
 908 AC_DEFUN([CF_CC_ENV_FLAGS],
 909 [
 910 # This should have been defined by AC_PROG_CC
 911 : "${CC:=cc}"
 912
 913 AC_MSG_CHECKING(\$CFLAGS variable)
 914 case "x$CFLAGS" in
 915 (*-[[IUD]]*)
 916         AC_MSG_RESULT(broken)
 917         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 918         cf_flags="$CFLAGS"
 919         CFLAGS=
 920         for cf_arg in $cf_flags
 921         do
 922                 CF_ADD_CFLAGS($cf_arg)
 923         done
 924         ;;
 925 (*)
 926         AC_MSG_RESULT(ok)
 927         ;;
 928 esac
 929
 930 AC_MSG_CHECKING(\$CC variable)
 931 case "$CC" in
 932 (*[[\ \ ]]-*)
 933         AC_MSG_RESULT(broken)
 934         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 935         # humor him...
 936         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 937         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 938         CC="$cf_prog"
 939         for cf_arg in $cf_flags
 940         do
 941                 case "x$cf_arg" in
 942                 (x-[[IUDfgOW]]*)
 943                         CF_ADD_CFLAGS($cf_arg)
 944                         ;;
 945                 (*)
 946                         CC="$CC $cf_arg"
 947                         ;;
 948                 esac
 949         done
 950         CF_VERBOSE(resulting CC: '$CC')
 951         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 952         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 953         ;;
 954 (*)
 955         AC_MSG_RESULT(ok)
 956         ;;
 957 esac
 958 ])dnl
 959 dnl ---------------------------------------------------------------------------
 960 dnl CF_CFG_DEFAULTS version: 16 updated: 2021/01/04 19:33:05
 961 dnl ---------------
 962 dnl Determine the default configuration into which we'll install ncurses.  This
 963 dnl can be overridden by the user's command-line options.  There's two items to
 964 dnl look for:
 965 dnl     1. the prefix (e.g., /usr)
 966 dnl     2. the header files (e.g., /usr/include/ncurses)
 967 dnl We'll look for a previous installation of ncurses and use the same defaults.
 968 dnl
 969 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 970 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 971 dnl programs from a vendor's.
 972 AC_DEFUN([CF_CFG_DEFAULTS],
 973 [AC_REQUIRE([AC_PROG_FGREP])dnl
 974
 975 AC_MSG_CHECKING(for prefix)
 976 if test "x$prefix" = "xNONE" ; then
 977         case "$cf_cv_system_name" in
 978                 # non-vendor systems don't have a conflict
 979         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 980                 prefix=/usr
 981                 ;;
 982         (*)     prefix=$ac_default_prefix
 983                 ;;
 984         esac
 985 fi
 986 AC_MSG_RESULT($prefix)
 987
 988 if test "x$prefix" = "xNONE" ; then
 989 AC_MSG_CHECKING(for default include-directory)
 990 test -n "$verbose" && echo 1>&AC_FD_MSG
 991 for cf_symbol in \
 992         "$includedir" \
 993         "$includedir/ncurses" \
 994         "$prefix/include" \
 995         "$prefix/include/ncurses" \
 996         /usr/local/include \
 997         /usr/local/include/ncurses \
 998         /usr/include \
 999         /usr/include/ncurses
1000 do
1001         cf_dir=`eval echo "$cf_symbol"`
1002         if test -f "$cf_dir/curses.h" ; then
1003         if ( ${FGREP-fgrep} NCURSES_VERSION "$cf_dir/curses.h" >/dev/null 2>&1 ) ; then
1004                 includedir="$cf_symbol"
1005                 test -n "$verbose"  && echo $ECHO_N "   found " 1>&AC_FD_MSG
1006                 break
1007         fi
1008         fi
1009         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
1010 done
1011 AC_MSG_RESULT($includedir)
1012 fi
1013 ])dnl
1014 dnl ---------------------------------------------------------------------------
1015 dnl CF_CGETENT version: 6 updated: 2017/01/21 11:06:25
1016 dnl ----------
1017 dnl Check if the terminal-capability database functions are available.  If not,
1018 dnl ncurses has a much-reduced version.
1019 AC_DEFUN([CF_CGETENT],[
1020 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
1021 AC_TRY_LINK([
1022 #include <stdlib.h>],[
1023         char temp[128];
1024         char *buf = temp;
1025         char *db_array = temp;
1026         cgetent(&buf, &db_array, "vt100");
1027         cgetcap(buf, "tc", '=');
1028         cgetmatch(buf, "tc");
1029         ],
1030         [cf_cv_cgetent=yes],
1031         [cf_cv_cgetent=no])
1032 ])
1033
1034 if test "$cf_cv_cgetent" = yes
1035 then
1036         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
1037 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
1038 AC_TRY_LINK([
1039 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
1040 #include <stdlib.h>],[
1041         char temp[128];
1042         char *buf = temp;
1043 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
1044         const char *db_array = temp;
1045         cgetent(&buf, &db_array, "vt100");
1046 #endif
1047         cgetcap(buf, "tc", '=');
1048         cgetmatch(buf, "tc");
1049         ],
1050         [cf_cv_cgetent_const=yes],
1051         [cf_cv_cgetent_const=no])
1052 ])
1053         if test "$cf_cv_cgetent_const" = yes
1054         then
1055                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
1056         fi
1057 fi
1058 ])dnl
1059 dnl ---------------------------------------------------------------------------
1060 dnl CF_CHECK_CACHE version: 13 updated: 2020/12/31 10:54:15
1061 dnl --------------
1062 dnl Check if we're accidentally using a cache from a different machine.
1063 dnl Derive the system name, as a check for reusing the autoconf cache.
1064 dnl
1065 dnl If we've packaged config.guess and config.sub, run that (since it does a
1066 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
1067 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
1068 dnl which is useful in cross-compiles.
1069 dnl
1070 dnl Note: we would use $ac_config_sub, but that is one of the places where
1071 dnl autoconf 2.5x broke compatibility with autoconf 2.13
1072 AC_DEFUN([CF_CHECK_CACHE],
1073 [
1074 if test -f "$srcdir/config.guess" || test -f "$ac_aux_dir/config.guess" ; then
1075         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
1076         system_name="$host_os"
1077 else
1078         system_name="`(uname -s -r) 2>/dev/null`"
1079         if test -z "$system_name" ; then
1080                 system_name="`(hostname) 2>/dev/null`"
1081         fi
1082 fi
1083 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
1084 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
1085
1086 test -z "$system_name" && system_name="$cf_cv_system_name"
1087 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
1088
1089 if test ".$system_name" != ".$cf_cv_system_name" ; then
1090         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
1091         AC_MSG_ERROR("Please remove config.cache and try again.")
1092 fi
1093 ])dnl
1094 dnl ---------------------------------------------------------------------------
1095 dnl CF_CHECK_ENVIRON version: 3 updated: 2010/05/26 16:44:57
1096 dnl ----------------
1097 dnl Check for data that is usually declared in <unistd.h>, e.g., the 'environ'
1098 dnl variable.  Define a DECL_xxx symbol if we must declare it ourselves.
1099 dnl
1100 dnl $1 = the name to check
1101 dnl $2 = the assumed type
1102 AC_DEFUN([CF_CHECK_ENVIRON],
1103 [
1104 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1105     AC_TRY_COMPILE([
1106 #ifdef HAVE_STDLIB_H
1107 #include <stdlib.h>
1108 #endif
1109 #include <unistd.h> ],
1110     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
1111     [cf_cv_dcl_$1=yes],
1112     [cf_cv_dcl_$1=no])
1113 ])
1114
1115 if test "$cf_cv_dcl_$1" = no ; then
1116     CF_UPPER(cf_result,decl_$1)
1117     AC_DEFINE_UNQUOTED($cf_result)
1118 fi
1119
1120 # It's possible (for near-UNIX clones) that the data doesn't exist
1121 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1122 ])dnl
1123 dnl ---------------------------------------------------------------------------
1124 dnl CF_CHECK_ERRNO version: 13 updated: 2020/03/10 18:53:47
1125 dnl --------------
1126 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
1127 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
1128 dnl ourselves.
1129 dnl
1130 dnl $1 = the name to check
1131 dnl $2 = the assumed type
1132 AC_DEFUN([CF_CHECK_ERRNO],
1133 [
1134 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1135         AC_TRY_COMPILE([
1136 #ifdef HAVE_STDLIB_H
1137 #include <stdlib.h>
1138 #endif
1139 #include <stdio.h>
1140 #include <sys/types.h>
1141 #include <errno.h> ],
1142         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1; (void)x,
1143         [cf_cv_dcl_$1=yes],
1144         [cf_cv_dcl_$1=no])
1145 ])
1146
1147 if test "$cf_cv_dcl_$1" = no ; then
1148         CF_UPPER(cf_result,decl_$1)
1149         AC_DEFINE_UNQUOTED($cf_result)
1150 fi
1151
1152 # It's possible (for near-UNIX clones) that the data doesn't exist
1153 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1154 ])dnl
1155 dnl ---------------------------------------------------------------------------
1156 dnl CF_CHECK_EXTERN_DATA version: 5 updated: 2021/09/04 06:35:04
1157 dnl --------------------
1158 dnl Check for existence of external data in the current set of libraries.  If
1159 dnl we can modify it, it is real enough.
1160 dnl $1 = the name to check
1161 dnl $2 = its type
1162 AC_DEFUN([CF_CHECK_EXTERN_DATA],
1163 [
1164 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
1165         AC_TRY_LINK([
1166 #undef $1
1167 extern $2 $1;
1168 ],
1169         [$1 = 2],
1170         [cf_cv_have_$1=yes],
1171         [cf_cv_have_$1=no])
1172 ])
1173
1174 if test "$cf_cv_have_$1" = yes ; then
1175         CF_UPPER(cf_result,have_$1)
1176         AC_DEFINE_UNQUOTED($cf_result)
1177 fi
1178
1179 ])dnl
1180 dnl ---------------------------------------------------------------------------
1181 dnl CF_CHECK_FVISIBILITY version: 2 updated: 2020/04/04 16:16:13
1182 dnl --------------------
1183 dnl Check whether the compiler understands -fvisibility=hidden
1184 dnl
1185 dnl $1 = compiler
1186 dnl $2 = compiler-flags variable name
1187 dnl $3 = cache variable to set
1188 AC_DEFUN([CF_CHECK_FVISIBILITY],[
1189 AC_CACHE_CHECK(if $1 -fvisibility=hidden option works,$3,[
1190     cf_save_cflags="[$]$2"
1191     $2="[$]$2 -fvisibility=hidden"
1192     AC_TRY_LINK([
1193 __attribute__ ((visibility("default"))) int somefunc() {return 42;}
1194         ],[
1195         if (somefunc()) return 1;
1196 ],
1197     [$3=yes],
1198     [$3=no])
1199     $2=$cf_save_cflags
1200 ])
1201 ])dnl
1202 dnl ---------------------------------------------------------------------------
1203 dnl CF_CHECK_GETENV version: 2 updated: 2021/01/02 17:09:14
1204 dnl ---------------
1205 dnl Check if repeated getenv calls return the same pointer, e.g., it does not
1206 dnl discard the previous pointer when returning a new one.
1207 AC_DEFUN([CF_CHECK_GETENV],
1208 [
1209 AC_REQUIRE([CF_CHECK_ENVIRON])
1210 AC_CHECK_FUNC( getenv, ,, AC_MSG_ERROR(getenv not found) )
1211 AC_CHECK_FUNCS( putenv setenv strdup )
1212 AC_CACHE_CHECK(if getenv returns consistent values,cf_cv_consistent_getenv,[
1213 AC_TRY_RUN([
1214 #include <stdlib.h>
1215 #include <unistd.h>
1216 #include <stdio.h>
1217 #include <string.h>
1218 #include <sys/types.h>
1219
1220 #if defined(HAVE_ENVIRON) && defined(DECL_ENVIRON) && !defined(environ)
1221 extern char **environ;  /* POSIX, but some systems are not... */
1222 #endif
1223
1224 #if defined(HAVE_STRDUP)
1225 #define str_alloc(s) strdup(s)
1226 #else
1227 #define str_alloc(s) strcpy(malloc(strlen(s) + 1, s))
1228 #endif
1229
1230 static void set_value(const char *name, const char *value)
1231 {
1232 #if defined(HAVE_SETENV)
1233         setenv(name, value, 1);
1234 #elif defined(HAVE_PUTENV)
1235         char buffer[1024];
1236         sprintf(buffer, "%s=%s", name, value);
1237         putenv(str_alloc(buffer));
1238 #else
1239 #error neither putenv/setenv found
1240 #endif
1241 }
1242 int main(void)
1243 {
1244         int pass;
1245         size_t numenv, limit, j;
1246         char **mynames;
1247         char **myvalues;
1248         char **mypointer;
1249         char *equals;
1250         for (numenv = 0; environ[numenv]; ++numenv) ;
1251         limit = numenv + 10;
1252         mynames = (char **) calloc(limit + 1, sizeof(char *));
1253         myvalues = (char **) calloc(limit + 1, sizeof(char *));
1254         mypointer = (char **) calloc(limit + 1, sizeof(char *));
1255 #if defined(HAVE_ENVIRON)
1256         for (j = 0; environ[j]; ++j) {
1257                 mynames[j] = str_alloc(environ[j]);
1258                 equals = strchr(mynames[j], '=');
1259                 if (equals != 0) {
1260                         *equals++ = '\\0';
1261                         myvalues[j] = str_alloc(equals);
1262                 } else {
1263                         myvalues[j] = str_alloc("");
1264                 }
1265         }
1266 #endif
1267         for (j = numenv; j < limit; ++j) {
1268                 char name[80];
1269                 char value[80];
1270                 size_t found;
1271                 size_t k = 0;
1272                 do {
1273                         size_t jk;
1274                         found = 0;
1275                         sprintf(name, "TERM%lu", (unsigned long) k);
1276                         for (jk = 0; jk < j; ++jk) {
1277                                 if (!strcmp(name, mynames[jk])) {
1278                                         found = 1;
1279                                         ++k;
1280                                         break;
1281                                 }
1282                         }
1283                 } while (found);
1284                 sprintf(value, "%lu:%p", (unsigned long) k, &mynames[j]);
1285                 set_value(name, value);
1286                 mynames[j] = str_alloc(name);
1287                 myvalues[j] = str_alloc(value);
1288         }
1289         for (pass = 0; pass < 3; ++pass) {
1290                 for (j = 0; j < limit; ++j) {
1291                         char *value = getenv(mynames[j]);
1292                         if (pass) {
1293                                 if (value == 0) {
1294                                         fprintf(stderr, "getenv returned null for %s\\n", mynames[j]);
1295                                         ${cf_cv_main_return:-return}(1);
1296                                 } else if (value != mypointer[j]) {
1297                                         fprintf(stderr, "getenv returned different pointer for %s\\n", mynames[j]);
1298                                         ${cf_cv_main_return:-return}(1);
1299                                 } else if (strcmp(value, myvalues[j])) {
1300                                         fprintf(stderr, "getenv returned different value for %s\\n", mynames[j]);
1301                                         ${cf_cv_main_return:-return}(1);
1302                                 }
1303                         } else {
1304                                 size_t k;
1305                                 mypointer[j] = value;
1306                                 for (k = 0; k < j; ++k) {
1307                                         if (mypointer[j] == mypointer[k]) {
1308                                                 fprintf(stderr, "getenv returned same pointer for %s and %s\\n", mynames[j], mynames[k]);
1309                                                 ${cf_cv_main_return:-return}(1);
1310                                         }
1311                                 }
1312                         }
1313                 }
1314         }
1315         ${cf_cv_main_return:-return}(0);
1316 }
1317 ],
1318 [cf_cv_consistent_getenv=yes],
1319 [cf_cv_consistent_getenv=no],
1320 [cf_cv_consistent_getenv=unknown])
1321 ])
1322
1323 if test "x$cf_cv_consistent_getenv" = xno
1324 then
1325         AC_DEFINE(HAVE_CONSISTENT_GETENV,1,[Define to 1 if getenv repeatably returns the same value for a given name])
1326 fi
1327 ])dnl
1328 dnl ---------------------------------------------------------------------------
1329 dnl CF_CHECK_GNAT_VERSION version: 4 updated: 2021/01/01 13:31:04
1330 dnl ---------------------
1331 AC_DEFUN([CF_CHECK_GNAT_VERSION],
1332 [
1333 AC_REQUIRE([CF_GNAT_VERSION])
1334 case "$cf_cv_gnat_version" in
1335 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
1336         cf_cv_prog_gnat_correct=yes
1337         ;;
1338 (*)
1339         AC_MSG_WARN(Unsupported GNAT version $cf_cv_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1340         cf_cv_prog_gnat_correct=no
1341         ;;
1342 esac
1343 ])
1344 dnl ---------------------------------------------------------------------------
1345 dnl CF_CHECK_GPM_WGETCH version: 6 updated: 2021/01/04 18:48:01
1346 dnl -------------------
1347 dnl Check if GPM is already linked with curses.  If so - and if the linkage
1348 dnl is not "weak" - warn about this because it can create problems linking
1349 dnl applications with ncurses.
1350 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
1351 AC_REQUIRE([AC_PROG_EGREP])dnl
1352
1353 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
1354
1355 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
1356 cf_cv_check_gpm_wgetch=unknown
1357 if test "$cross_compiling" != yes ; then
1358
1359 cat >conftest.$ac_ext <<CF_EOF
1360 #include <gpm.h>
1361 int main(void)
1362 {
1363         Gpm_Wgetch();
1364         ${cf_cv_main_return:-return}(0);
1365 }
1366 CF_EOF
1367
1368         cf_save_LIBS="$LIBS"
1369         # This only works if we can look at the symbol table.  If a shared
1370         # library is stripped for install, we cannot use that.  So we're forced
1371         # to rely on the static library, noting that some packagers may not
1372         # include it.
1373         LIBS="-static -lgpm -dynamic $LIBS"
1374         if AC_TRY_EVAL(ac_compile) ; then
1375                 if AC_TRY_EVAL(ac_link) ; then
1376                         cf_cv_check_gpm_wgetch="`nm \"conftest$ac_exeext\" | ${EGREP-egrep} '\<wgetch\>' | ${EGREP-egrep} '\<[[vVwW]]\>'`"
1377                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
1378                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
1379                 fi
1380         fi
1381         rm -rf ./conftest*
1382         LIBS="$cf_save_LIBS"
1383 fi
1384 ])
1385
1386 if test "$cf_cv_check_gpm_wgetch" != yes ; then
1387         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
1388 fi
1389 ])])dnl
1390 dnl ---------------------------------------------------------------------------
1391 dnl CF_CHECK_LIBSSP version: 1 updated: 2021/10/30 10:40:19
1392 dnl ---------------
1393 dnl Check if libssp is needed, e.g., to work around misconfigured libraries
1394 dnl used in cross-compiling to MinGW.
1395 AC_DEFUN([CF_CHECK_LIBSSP],[
1396 AC_CACHE_CHECK(if ssp library is needed,cf_cv_need_libssp,[
1397 AC_TRY_LINK([
1398 #include <sys/types.h>
1399 #include <dirent.h>
1400 ],[
1401        DIR *dp = opendir(".");
1402 ],cf_cv_need_libssp=no,[
1403         cf_save_LIBS="$LIBS"
1404         LIBS="$LIBS -lssp"
1405         AC_TRY_LINK([
1406 #include <sys/types.h>
1407 #include <dirent.h>
1408         ],[
1409                    DIR *dp = opendir(".");
1410         ],cf_cv_need_libssp=yes,
1411           cf_cv_need_libssp=maybe)
1412         LIBS="$cf_save_LIBS"
1413 ])dnl
1414 ])
1415
1416 if test "x$cf_cv_need_libssp" = xyes
1417 then
1418         CF_ADD_LIB(ssp)
1419 fi
1420 ])dnl
1421 dnl ---------------------------------------------------------------------------
1422 dnl CF_CHECK_LIBTOOL_VERSION version: 2 updated: 2021/05/01 16:24:34
1423 dnl ------------------------
1424 dnl Show the version of libtool
1425 dnl
1426 dnl Save the version in a cache variable - this is not entirely a good thing,
1427 dnl but the version string from libtool is very ugly, and for bug reports it
1428 dnl might be useful to have the original string.
1429 dnl
1430 dnl There is an imitation in OpenBSD, which has no apparent use other than to
1431 dnl deny that it is GNU libtool.  Just ignore it.
1432 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1433 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1434 then
1435         AC_MSG_CHECKING(version of $LIBTOOL)
1436         CF_LIBTOOL_VERSION
1437         AC_MSG_RESULT($cf_cv_libtool_version)
1438         if test -n "$cf_cv_libtool_version"
1439         then
1440                 cf_check_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' -e 's,[[()]],...,g' -e 's,[[ ]],-,g' -e '2,$d'`
1441                 case "x$cf_check_libtool_version" in
1442                 (*...GNU-libtool...*)
1443                         ;;
1444                 (*)
1445                         AC_MSG_ERROR(This is not GNU libtool)
1446                         ;;
1447                 esac
1448         else
1449                 AC_MSG_ERROR(No version found for $LIBTOOL)
1450         fi
1451 else
1452         AC_MSG_ERROR(GNU libtool has not been found)
1453 fi
1454 ])dnl
1455 dnl ---------------------------------------------------------------------------
1456 dnl CF_CHECK_WCHAR_H version: 3 updated: 2021/01/01 13:31:04
1457 dnl ----------------
1458 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1459 AC_DEFUN([CF_CHECK_WCHAR_H],[
1460 AC_CHECK_HEADERS( \
1461 wchar.h \
1462 wctype.h \
1463 )
1464 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1465 AC_TRY_COMPILE(
1466 [
1467 #include <stdlib.h>
1468 #ifdef HAVE_WCHAR_H
1469 #include <wchar.h>
1470 #endif
1471 #ifdef HAVE_WCTYPE_H
1472 #include <wctype.h>
1473 #endif
1474 ],[
1475         wint_t foo = 0;
1476         int bar = iswpunct(foo)],
1477         [cf_cv_wchar_h_okay=yes],
1478         [cf_cv_wchar_h_okay=no])])
1479
1480 if test "$cf_cv_wchar_h_okay" = no
1481 then
1482         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1483 fi
1484 ])dnl
1485 dnl ---------------------------------------------------------------------------
1486 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 2 updated: 2021/01/02 17:09:14
1487 dnl -------------------------
1488 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1489 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1490 dnl
1491 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1492 dnl all of those were combined into a page of useful graphics characters.
1493 dnl
1494 dnl So far, so good.
1495 dnl
1496 dnl However, while they are useful, there are other considerations.  CJK
1497 dnl is (because of poor device resolution) often rendered as double-width
1498 dnl characters.  So... for these generally-useful characters, what should
1499 dnl be the width (to make them consistent with adjacent characters)?
1500 dnl
1501 dnl The obvious choice would have been to make this locale-dependent, and use
1502 dnl wcwidth() to tell applications what the actual width is.  That was too
1503 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1504 dnl See for example
1505 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1506 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1507 dnl
1508 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1509 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1510 dnl instance, it lists half (44/96) of the Latin-1 characters as
1511 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1512 dnl
1513 dnl What this means for the implementor is that on some systems wcwidth() can
1514 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1515 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1516 dnl characters).  These do not necessarily match the behavior of the terminal
1517 dnl emulator.  xterm, for instance, does an optional startup check to find if
1518 dnl this problem (or similar) exists with the system's locale tables, rejecting
1519 dnl them if they are too unreliable.
1520 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1521 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1522 cat >conftest.in <<CF_EOF
1523 -       VT100 symbols
1524 0x250c  upper left corner
1525 0x2514  lower left corner
1526 0x2510  upper right corner
1527 0x2518  lower right corner
1528 0x251c  tee pointing left
1529 0x2524  tee pointing right
1530 0x2534  tee pointing up
1531 0x252c  tee pointing down
1532 0x2500  horizontal line
1533 0x2502  vertical line
1534 0x253c  large plus or crossover
1535 0x23ba  scan line 1
1536 0x23bd  scan line 9
1537 0x25c6  diamond
1538 0x2592  checker board (stipple)
1539 0x00b0  degree symbol
1540 0x00b1  plus/minus
1541 0x00b7  bullet
1542 -       Teletype 5410v1 symbols
1543 0x2190  arrow pointing left
1544 0x2192  arrow pointing right
1545 0x2193  arrow pointing down
1546 0x2191  arrow pointing up
1547 0x2592  board of squares
1548 0x2603  lantern symbol
1549 0x25ae  solid square block
1550 -       these defaults were invented for ncurses
1551 0x23bb  scan line 3
1552 0x23bc  scan line 7
1553 0x2264  less-than-or-equal-to
1554 0x2265  greater-than-or-equal-to
1555 0x03c0  greek pi
1556 0x2260  not-equal
1557 0x00a3  pound-sterling symbol
1558 -       thick-line-drawing
1559 0x250f  upper left corner
1560 0x2517  lower left corner
1561 0x2513  upper right corner
1562 0x251b  lower right corner
1563 0x2523  tee pointing left
1564 0x252b  tee pointing right
1565 0x253b  tee pointing up
1566 0x2533  tee pointing down
1567 0x2501  horizontal line
1568 0x2503  vertical line
1569 0x254b  large plus or crossover
1570 -       double-line-drawing
1571 0x2554  upper left corner
1572 0x255a  lower left corner
1573 0x2557  upper right corner
1574 0x255d  lower right corner
1575 0x2563  tee pointing left
1576 0x2560  tee pointing right
1577 0x2569  tee pointing up
1578 0x2566  tee pointing down
1579 0x2550  horizontal line
1580 0x2551  vertical line
1581 0x256c  large plus or crossover
1582 CF_EOF
1583 AC_TRY_RUN([
1584 #include <locale.h>
1585 #include <stdio.h>
1586 #include <wchar.h>
1587
1588 #define MY_LEN 80
1589
1590 int
1591 main(void)
1592 {
1593         FILE *fp;
1594         int value;
1595         char buffer[MY_LEN + 1];
1596         char notes[MY_LEN + 1];
1597         int totals = 0;
1598         int passed = 0;
1599
1600         if (setlocale(LC_ALL, "en_US.UTF8") ||
1601                 setlocale(LC_ALL, "en_US.UTF-8") ||
1602                 setlocale(LC_ALL, "en_US.utf8") ||
1603                 setlocale(LC_ALL, "en_US.utf-8")) {
1604                 if ((fp = fopen("conftest.in", "r")) != 0) {
1605                         while (fgets(buffer, MY_LEN, fp) != 0) {
1606                                 if (*buffer == '-') {
1607                                         fprintf(stderr, "\\t%s", buffer);
1608                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1609                                         ++totals;
1610                                         if (wcwidth(value) == 1)
1611                                                 ++passed;
1612                                         fprintf(stderr, "%d\\t%s", wcwidth(value), buffer);
1613                                 } else {
1614                                         fprintf(stderr, "?\\t%s", buffer);
1615                                 }
1616                         }
1617                 }
1618         }
1619         fprintf(stderr, "%d/%d passed wcwidth/graphics check\\n", passed, totals);
1620         return (totals == passed) ? 0 : 1;
1621 }
1622 ],
1623 [cf_cv_wcwidth_graphics=yes],
1624 [cf_cv_wcwidth_graphics=no],
1625 [cf_cv_wcwidth_graphics=unknown])
1626 ])
1627 ])dnl
1628 dnl ---------------------------------------------------------------------------
1629 dnl CF_CLANG_COMPILER version: 8 updated: 2021/01/01 13:31:04
1630 dnl -----------------
1631 dnl Check if the given compiler is really clang.  clang's C driver defines
1632 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1633 dnl not ignore some gcc options.
1634 dnl
1635 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1636 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1637 dnl the wrappers for gcc and g++ warnings.
1638 dnl
1639 dnl $1 = GCC (default) or GXX
1640 dnl $2 = CLANG_COMPILER (default)
1641 dnl $3 = CFLAGS (default) or CXXFLAGS
1642 AC_DEFUN([CF_CLANG_COMPILER],[
1643 ifelse([$2],,CLANG_COMPILER,[$2])=no
1644
1645 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1646         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1647         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1648         AC_TRY_COMPILE([],[
1649 #ifdef __clang__
1650 #else
1651 make an error
1652 #endif
1653 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1654 ],[])
1655         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1656         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1657 fi
1658
1659 CLANG_VERSION=none
1660
1661 if test "x$ifelse([$2],,CLANG_COMPILER,[$2])" = "xyes" ; then
1662         case "$CC" in
1663         (c[[1-9]][[0-9]]|*/c[[1-9]][[0-9]])
1664                 AC_MSG_WARN(replacing broken compiler alias $CC)
1665                 CFLAGS="$CFLAGS -std=`echo "$CC" | sed -e 's%.*/%%'`"
1666                 CC=clang
1667                 ;;
1668         esac
1669
1670         AC_MSG_CHECKING(version of $CC)
1671         CLANG_VERSION="`$CC --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(CLANG[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1672         test -z "$CLANG_VERSION" && CLANG_VERSION=unknown
1673         AC_MSG_RESULT($CLANG_VERSION)
1674
1675         for cf_clang_opt in \
1676                 -Qunused-arguments \
1677                 -Wno-error=implicit-function-declaration
1678         do
1679                 AC_MSG_CHECKING(if option $cf_clang_opt works)
1680                 cf_save_CFLAGS="$CFLAGS"
1681                 CFLAGS="$CFLAGS $cf_clang_opt"
1682                 AC_TRY_LINK([
1683                         #include <stdio.h>],[
1684                         printf("hello!\\n");],[
1685                         cf_clang_optok=yes],[
1686                         cf_clang_optok=no])
1687                 AC_MSG_RESULT($cf_clang_optok)
1688                 CFLAGS="$cf_save_CFLAGS"
1689                 if test "$cf_clang_optok" = yes; then
1690                         CF_VERBOSE(adding option $cf_clang_opt)
1691                         CF_APPEND_TEXT(CFLAGS,$cf_clang_opt)
1692                 fi
1693         done
1694 fi
1695 ])
1696 dnl ---------------------------------------------------------------------------
1697 dnl CF_CONST_X_STRING version: 7 updated: 2021/06/07 17:39:17
1698 dnl -----------------
1699 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
1700 dnl character-strings.
1701 dnl
1702 dnl It is ambiguous because the specification accommodated the pre-ANSI
1703 dnl compilers bundled by more than one vendor in lieu of providing a standard C
1704 dnl compiler other than by costly add-ons.  Because of this, the specification
1705 dnl did not take into account the use of const for telling the compiler that
1706 dnl string literals would be in readonly memory.
1707 dnl
1708 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
1709 dnl let the compiler decide how to represent Xt's strings which were #define'd.
1710 dnl That does not solve the problem of using the block of Xt's strings which
1711 dnl are compiled into the library (and is less efficient than one might want).
1712 dnl
1713 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
1714 dnl when compiling the library and compiling using the library, to tell the
1715 dnl compiler that String is const.
1716 AC_DEFUN([CF_CONST_X_STRING],
1717 [
1718 AC_REQUIRE([AC_PATH_XTRA])
1719
1720 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
1721
1722 AC_TRY_COMPILE(
1723 [
1724 #include <stdlib.h>
1725 #include <X11/Intrinsic.h>
1726 ],
1727 [String foo = malloc(1); free((void*)foo)],[
1728
1729 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
1730         AC_TRY_COMPILE(
1731                 [
1732 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
1733 #undef  XTSTRINGDEFINES /* X11R5 and later */
1734 #include <stdlib.h>
1735 #include <X11/Intrinsic.h>
1736                 ],[String foo = malloc(1); *foo = 0],[
1737                         cf_cv_const_x_string=no
1738                 ],[
1739                         cf_cv_const_x_string=yes
1740                 ])
1741 ])
1742
1743 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
1744
1745 case "$cf_cv_const_x_string" in
1746 (no)
1747         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
1748         ;;
1749 (*)
1750         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
1751         ;;
1752 esac
1753
1754 ])
1755 ])dnl
1756 dnl ---------------------------------------------------------------------------
1757 dnl CF_CPP_OVERRIDE version: 1 updated: 2022/08/20 16:07:10
1758 dnl ---------------
1759 dnl Check if the C++ compiler accepts the override keyword.  This is a C++-11
1760 dnl feature.
1761 AC_DEFUN([CF_CPP_OVERRIDE],
1762 [
1763 if test -n "$CXX"; then
1764 AC_CACHE_CHECK(if $CXX accepts override keyword,cf_cv_cpp_override,[
1765         AC_LANG_SAVE
1766         AC_LANG_CPLUSPLUS
1767         AC_TRY_RUN([
1768
1769 class base
1770 {
1771 public:
1772         virtual int foo(float x) = 0;
1773 };
1774
1775
1776 class derived: public base
1777 {
1778 public:
1779         int foo(float x) override { return x != 0.0 ? 1 : 0; }
1780 };
1781
1782 int main(void) { }
1783 ],
1784         [cf_cv_cpp_override=yes],
1785         [cf_cv_cpp_override=no],
1786         [cf_cv_cpp_override=unknown])
1787         AC_LANG_RESTORE
1788 ])
1789 fi
1790 test "$cf_cv_cpp_override" = yes && AC_DEFINE(CPP_HAS_OVERRIDE,1,[Define to 1 if C++ has override keyword])
1791 ])dnl
1792 dnl ---------------------------------------------------------------------------
1793 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1794 dnl -----------------
1795 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1796 dnl is a late feature for the standard and is not in some recent compilers
1797 dnl (1999/9/11).
1798 AC_DEFUN([CF_CPP_PARAM_INIT],
1799 [
1800 if test -n "$CXX"; then
1801 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1802         AC_LANG_SAVE
1803         AC_LANG_CPLUSPLUS
1804         AC_TRY_RUN([
1805 class TEST {
1806 private:
1807         int value;
1808 public:
1809         TEST(int x = 1);
1810         ~TEST();
1811 };
1812
1813 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1814 {
1815         value = x;
1816 }
1817 int main(void) { }
1818 ],
1819         [cf_cv_cpp_param_init=yes],
1820         [cf_cv_cpp_param_init=no],
1821         [cf_cv_cpp_param_init=unknown])
1822         AC_LANG_RESTORE
1823 ])
1824 fi
1825 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1826 ])dnl
1827 dnl ---------------------------------------------------------------------------
1828 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1829 dnl ------------------
1830 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1831 dnl not be supported in g++ before 3.0
1832 AC_DEFUN([CF_CPP_STATIC_CAST],
1833 [
1834 if test -n "$CXX"; then
1835
1836 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1837         AC_LANG_SAVE
1838         AC_LANG_CPLUSPLUS
1839
1840         AC_TRY_COMPILE([
1841 class NCursesPanel
1842 {
1843 public:
1844   NCursesPanel(int nlines,
1845                int ncols,
1846                int begin_y = 0,
1847                int begin_x = 0)
1848   {
1849   }
1850   NCursesPanel();
1851   ~NCursesPanel();
1852 };
1853
1854 template<class T> class NCursesUserPanel : public NCursesPanel
1855 {
1856 public:
1857   NCursesUserPanel (int nlines,
1858                     int ncols,
1859                     int begin_y = 0,
1860                     int begin_x = 0,
1861                     const T* p_UserData = static_cast<T*>(0))
1862     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1863   {
1864   };
1865   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1866   {
1867   };
1868
1869   virtual ~NCursesUserPanel() {};
1870 };
1871 ],[
1872         const char* p_UserData = static_cast<char*>(0)],
1873         [cf_cv_cpp_static_cast=yes],
1874         [cf_cv_cpp_static_cast=no])
1875
1876         AC_LANG_RESTORE
1877 ])
1878
1879 fi
1880
1881 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1882 ])dnl
1883 dnl ---------------------------------------------------------------------------
1884 dnl CF_CXX_AR_FLAGS version: 3 updated: 2021/01/01 13:31:04
1885 dnl ---------------
1886 dnl Setup special archiver flags for given compilers.
1887 AC_DEFUN([CF_CXX_AR_FLAGS],[
1888         CXX_AR='$(AR)'
1889         CXX_ARFLAGS='$(ARFLAGS)'
1890         case "$cf_cv_system_name" in
1891         (irix*)
1892             if test "$GXX" != yes ; then
1893                 CXX_AR='$(CXX)'
1894                 CXX_ARFLAGS='-ar -o'
1895             fi
1896             ;;
1897         (sco3.2v5*)
1898             CXXLDFLAGS="-u main"
1899             ;;
1900         (solaris2*)
1901             if test "$GXX" != yes ; then
1902                 CXX_AR='$(CXX)'
1903                 CXX_ARFLAGS='-xar -o'
1904             fi
1905             ;;
1906         esac
1907         AC_SUBST(CXXLDFLAGS)
1908         AC_SUBST(CXX_AR)
1909         AC_SUBST(CXX_ARFLAGS)
1910 ])dnl
1911 dnl ---------------------------------------------------------------------------
1912 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1913 dnl -------------------------
1914 dnl For c++, check if iostream uses "std::" namespace.
1915 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1916 AC_CHECK_HEADERS(iostream)
1917 if test x"$ac_cv_header_iostream" = xyes ; then
1918         AC_MSG_CHECKING(if iostream uses std-namespace)
1919         AC_TRY_COMPILE([
1920 #include <iostream>
1921 using std::endl;
1922 using std::cerr;],[
1923 cerr << "testing" << endl;
1924 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1925         AC_MSG_RESULT($cf_iostream_namespace)
1926         if test "$cf_iostream_namespace" = yes ; then
1927                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1928         fi
1929 fi
1930 ])dnl
1931 dnl ---------------------------------------------------------------------------
1932 dnl CF_C_INLINE version: 6 updated: 2019/09/07 13:38:36
1933 dnl -----------
1934 dnl Check if the C compiler supports "inline".
1935 dnl $1 is the name of a shell variable to set if inline is supported
1936 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1937 AC_DEFUN([CF_C_INLINE],[
1938 AC_REQUIRE([CF_GCC_VERSION])
1939 AC_C_INLINE
1940 $1=
1941 if test "$ac_cv_c_inline" != no ; then
1942         $1=inline
1943         if test "$INTEL_COMPILER" = yes
1944         then
1945                 :
1946         elif test "$CLANG_COMPILER" = yes
1947         then
1948                 :
1949         elif test "$GCC" = yes
1950         then
1951                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1952                 cf_save_CFLAGS=$CFLAGS
1953                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1954                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1955                 [${cf_cv_main_return:-return} foo()],
1956                 [cf_cv_gcc_inline=yes],
1957                 [cf_cv_gcc_inline=no])
1958                 CFLAGS=$cf_save_CFLAGS
1959                 ])
1960                 if test "$cf_cv_gcc_inline" = yes ; then
1961                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1962                 fi
1963         fi
1964 fi
1965 AC_SUBST($1)
1966 ])dnl
1967 dnl ---------------------------------------------------------------------------
1968 dnl CF_DIRNAME version: 5 updated: 2020/12/31 20:19:42
1969 dnl ----------
1970 dnl "dirname" is not portable, so we fake it with a shell script.
1971 AC_DEFUN([CF_DIRNAME],[$1=`echo "$2" | sed -e 's%/[[^/]]*$%%'`])dnl
1972 dnl ---------------------------------------------------------------------------
1973 dnl CF_DIRS_TO_MAKE version: 4 updated: 2021/01/01 13:31:04
1974 dnl ---------------
1975 AC_DEFUN([CF_DIRS_TO_MAKE],
1976 [
1977 DIRS_TO_MAKE="lib"
1978 for cf_item in $cf_list_models
1979 do
1980         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1981         for cf_item2 in $DIRS_TO_MAKE
1982         do
1983                 test "$cf_item2" = "$cf_subdir" && break
1984         done
1985         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1986 done
1987 for cf_dir in $DIRS_TO_MAKE
1988 do
1989         test ! -d "$cf_dir" && mkdir "$cf_dir"
1990 done
1991 AC_SUBST(DIRS_TO_MAKE)
1992 ])dnl
1993 dnl ---------------------------------------------------------------------------
1994 dnl CF_DISABLE_ECHO version: 14 updated: 2021/09/04 06:35:04
1995 dnl ---------------
1996 dnl You can always use "make -n" to see the actual options, but it is hard to
1997 dnl pick out/analyze warning messages when the compile-line is long.
1998 dnl
1999 dnl Sets:
2000 dnl     ECHO_LT - symbol to control if libtool is verbose
2001 dnl     ECHO_LD - symbol to prefix "cc -o" lines
2002 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
2003 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
2004 dnl     ECHO_CC - symbol to put before any "cc" line
2005 dnl
2006 AC_DEFUN([CF_DISABLE_ECHO],[
2007 AC_MSG_CHECKING(if you want to see long compiling messages)
2008 CF_ARG_DISABLE(echo,
2009         [  --disable-echo          do not display "compiling" commands],
2010         [
2011         ECHO_LT='--silent'
2012         ECHO_LD='@echo linking [$]@;'
2013         RULE_CC='@echo compiling [$]<'
2014         SHOW_CC='@echo compiling [$]@'
2015         ECHO_CC='@'
2016 ],[
2017         ECHO_LT=''
2018         ECHO_LD=''
2019         RULE_CC=''
2020         SHOW_CC=''
2021         ECHO_CC=''
2022 ])
2023 AC_MSG_RESULT($enableval)
2024 AC_SUBST(ECHO_LT)
2025 AC_SUBST(ECHO_LD)
2026 AC_SUBST(RULE_CC)
2027 AC_SUBST(SHOW_CC)
2028 AC_SUBST(ECHO_CC)
2029 ])dnl
2030 dnl ---------------------------------------------------------------------------
2031 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
2032 dnl ------------------------
2033 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
2034 AC_MSG_CHECKING(if we want to use GNAT projects)
2035 CF_ARG_DISABLE(gnat-projects,
2036         [  --disable-gnat-projects test: disable GNAT projects even if usable],
2037         [enable_gnat_projects=no],
2038         [enable_gnat_projects=yes])
2039 AC_MSG_RESULT($enable_gnat_projects)
2040 ])dnl
2041 dnl ---------------------------------------------------------------------------
2042 dnl CF_DISABLE_LEAKS version: 9 updated: 2021/04/03 16:41:50
2043 dnl ----------------
2044 dnl Combine no-leak checks with the libraries or tools that are used for the
2045 dnl checks.
2046 AC_DEFUN([CF_DISABLE_LEAKS],[
2047
2048 AC_REQUIRE([CF_WITH_DMALLOC])
2049 AC_REQUIRE([CF_WITH_DBMALLOC])
2050 AC_REQUIRE([CF_WITH_VALGRIND])
2051
2052 AC_MSG_CHECKING(if you want to perform memory-leak testing)
2053 AC_ARG_ENABLE(leaks,
2054         [  --disable-leaks         test: free permanent memory, analyze leaks],
2055         [enable_leaks=$enableval],
2056         [enable_leaks=yes])
2057 dnl with_no_leaks is more readable...
2058 if test "x$enable_leaks" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi
2059 AC_MSG_RESULT($with_no_leaks)
2060
2061 if test "$enable_leaks" = no ; then
2062         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
2063         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
2064 fi
2065 ])dnl
2066 dnl ---------------------------------------------------------------------------
2067 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
2068 dnl --------------------------
2069 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
2070 dnl the older "-version-info" feature.  The newer feature allows us to use
2071 dnl version numbering on shared libraries which make them compatible with
2072 dnl various systems.
2073 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
2074 [
2075 AC_MSG_CHECKING(if libtool -version-number should be used)
2076 CF_ARG_DISABLE(libtool-version,
2077         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
2078         [cf_libtool_version=no],
2079         [cf_libtool_version=yes])
2080 AC_MSG_RESULT($cf_libtool_version)
2081
2082 if test "$cf_libtool_version" = yes ; then
2083         LIBTOOL_VERSION="-version-number"
2084 else
2085         LIBTOOL_VERSION="-version-info"
2086         case "x$VERSION" in
2087         (x)
2088                 AC_MSG_WARN(VERSION was not set)
2089                 ;;
2090         (x*.*.*)
2091                 ABI_VERSION="$VERSION"
2092                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
2093                 ;;
2094         (x*:*:*)
2095                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
2096                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
2097                 ;;
2098         (*)
2099                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
2100                 ;;
2101         esac
2102 fi
2103
2104 AC_SUBST(ABI_VERSION)
2105 AC_SUBST(LIBTOOL_VERSION)
2106 ])dnl
2107 dnl ---------------------------------------------------------------------------
2108 dnl CF_DISABLE_RPATH_HACK version: 3 updated: 2021/01/05 20:14:44
2109 dnl ---------------------
2110 dnl The rpath-hack makes it simpler to build programs, particularly with the
2111 dnl *BSD ports which may have essential libraries in unusual places.  But it
2112 dnl can interfere with building an executable for the base system.  Use this
2113 dnl option in that case.
2114 AC_DEFUN([CF_DISABLE_RPATH_HACK],
2115 [
2116 AC_MSG_CHECKING(if rpath-hack should be disabled)
2117 CF_ARG_DISABLE(rpath-hack,
2118         [  --disable-rpath-hack    don't add rpath options for additional libraries],
2119         [enable_rpath_hack=no],
2120         [enable_rpath_hack=yes])
2121 dnl TODO - drop cf_disable_rpath_hack
2122 if test "x$enable_rpath_hack" = xno; then cf_disable_rpath_hack=yes; else cf_disable_rpath_hack=no; fi
2123 AC_MSG_RESULT($cf_disable_rpath_hack)
2124
2125 if test "$enable_rpath_hack" = yes ; then
2126         CF_RPATH_HACK
2127 fi
2128 ])
2129 dnl ---------------------------------------------------------------------------
2130 dnl CF_ENABLE_BROKEN_LINKER version: 2 updated: 2021/01/02 17:09:14
2131 dnl -----------------------
2132 dnl Some linkers cannot reference a data-only object.  Cygwin used to be one.
2133 dnl This usually follows CF_LINK_DATAONLY, but is not required in case we need
2134 dnl an unconditional feature.
2135 AC_DEFUN([CF_ENABLE_BROKEN_LINKER],[
2136
2137 AC_MSG_CHECKING(if you want broken-linker support code)
2138 AC_ARG_ENABLE(broken_linker,
2139         [  --enable-broken_linker  compile with broken-linker support code],
2140         [with_broken_linker=$enableval],
2141         [with_broken_linker=no])
2142 AC_MSG_RESULT($with_broken_linker)
2143
2144 : "${BROKEN_LINKER:=0}"
2145 if test "x$with_broken_linker" = xyes ; then
2146         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
2147         BROKEN_LINKER=1
2148 fi
2149 AC_SUBST(BROKEN_LINKER)
2150 ])dnl
2151 dnl ---------------------------------------------------------------------------
2152 dnl CF_ENABLE_PC_FILES version: 16 updated: 2021/11/20 12:48:37
2153 dnl ------------------
2154 dnl This is the "--enable-pc-files" option, which is available if there is a
2155 dnl pkg-config configuration on the local machine.
2156 AC_DEFUN([CF_ENABLE_PC_FILES],[
2157 AC_REQUIRE([CF_PKG_CONFIG])
2158 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
2159
2160 if test "x$PKG_CONFIG" != xnone
2161 then
2162         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
2163 else
2164         AC_MSG_CHECKING(if we should install .pc files)
2165 fi
2166
2167 AC_ARG_ENABLE(pc-files,
2168         [  --enable-pc-files       generate and install .pc files for pkg-config],
2169         [enable_pc_files=$enableval],
2170         [enable_pc_files=no])
2171 AC_MSG_RESULT($enable_pc_files)
2172
2173 if test "x$enable_pc_files" != xno
2174 then
2175         MAKE_PC_FILES=
2176         case "x$PKG_CONFIG_LIBDIR" in
2177         (xno|xnone|xyes|x)
2178                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
2179                 ;;
2180         (*)
2181                 cf_pkg_config_libdir="$PKG_CONFIG_LIBDIR"
2182                 CF_PATH_SYNTAX(cf_pkg_config_libdir)
2183                 ;;
2184         esac
2185 else
2186         MAKE_PC_FILES="#"
2187 fi
2188 AC_SUBST(MAKE_PC_FILES)
2189 ])dnl
2190 dnl ---------------------------------------------------------------------------
2191 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
2192 dnl ---------------
2193 dnl Check if the rpath option should be used, setting cache variable
2194 dnl cf_cv_enable_rpath if so.
2195 AC_DEFUN([CF_ENABLE_RPATH],
2196 [
2197 AC_MSG_CHECKING(if rpath option should be used)
2198 AC_ARG_ENABLE(rpath,
2199 [  --enable-rpath          use rpath option when generating shared libraries],
2200 [cf_cv_enable_rpath=$enableval],
2201 [cf_cv_enable_rpath=no])
2202 AC_MSG_RESULT($cf_cv_enable_rpath)
2203 ])dnl
2204 dnl ---------------------------------------------------------------------------
2205 dnl CF_ENABLE_STRING_HACKS version: 6 updated: 2021/01/05 19:23:48
2206 dnl ----------------------
2207 dnl On a few platforms, the compiler and/or loader nags with untruthful
2208 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
2209 dnl and implying that most uses of the recommended alternatives are correct.
2210 dnl
2211 dnl Factually speaking, no one has actually counted the number of uses of these
2212 dnl functions versus the total of incorrect uses.  Samples of a few thousand
2213 dnl instances are meaningless compared to the hundreds of millions of lines of
2214 dnl existing C code.
2215 dnl
2216 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
2217 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
2218 dnl standard - but evolved through phases, and older implementations are likely
2219 dnl to yield surprising results, as documented in manpages on various systems.
2220 AC_DEFUN([CF_ENABLE_STRING_HACKS],
2221 [
2222 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
2223 AC_ARG_ENABLE(string-hacks,
2224         [  --enable-string-hacks   work around bogus compiler/loader warnings],
2225         [enable_string_hacks=$enableval],
2226         [enable_string_hacks=no])
2227 AC_MSG_RESULT($enable_string_hacks)
2228
2229 if test "x$enable_string_hacks" = "xyes"; then
2230         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
2231         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
2232         AC_CHECK_FUNC(strlcat,[
2233                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2234                 ],[
2235                 AC_CHECK_LIB(bsd,strlcat,[
2236                         CF_ADD_LIB(bsd)
2237                         AC_CHECK_HEADERS(bsd/string.h)
2238                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2239                         ])
2240                 ])
2241         AC_CHECK_FUNCS( strlcpy snprintf )
2242 fi
2243 ])dnl
2244 dnl ---------------------------------------------------------------------------
2245 dnl CF_ENABLE_WARNINGS version: 9 updated: 2021/01/05 19:40:50
2246 dnl ------------------
2247 dnl Configure-option to enable gcc warnings
2248 dnl
2249 dnl $1 = extra options to add, if supported
2250 dnl $2 = option for checking attributes.  By default, this is done when
2251 dnl      warnings are enabled.  For other values:
2252 dnl      yes: always do this, e.g., to use in generated library-headers
2253 dnl      no: never do this
2254 AC_DEFUN([CF_ENABLE_WARNINGS],[
2255 if test "$GCC" = yes || test "$GXX" = yes
2256 then
2257 CF_FIX_WARNINGS(CFLAGS)
2258 CF_FIX_WARNINGS(CPPFLAGS)
2259 CF_FIX_WARNINGS(LDFLAGS)
2260 AC_MSG_CHECKING(if you want to turn on gcc warnings)
2261 CF_ARG_ENABLE(warnings,
2262         [  --enable-warnings       test: turn on gcc compiler warnings],
2263         [enable_warnings=yes],
2264         [enable_warnings=no])
2265 AC_MSG_RESULT($enable_warnings)
2266 if test "$enable_warnings" = "yes"
2267 then
2268         ifelse($2,,[CF_GCC_ATTRIBUTES])
2269         CF_GCC_WARNINGS($1)
2270 fi
2271 ifelse($2,yes,[CF_GCC_ATTRIBUTES])
2272 fi
2273 ])dnl
2274 dnl ---------------------------------------------------------------------------
2275 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
2276 dnl --------
2277 dnl Check if 'errno' is declared in <errno.h>
2278 AC_DEFUN([CF_ERRNO],
2279 [
2280 CF_CHECK_ERRNO(errno)
2281 ])dnl
2282 dnl ---------------------------------------------------------------------------
2283 dnl CF_ETIP_DEFINES version: 6 updated: 2021/01/02 17:09:14
2284 dnl ---------------
2285 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
2286 dnl math.h and builtin.h, only for ncurses
2287 AC_DEFUN([CF_ETIP_DEFINES],
2288 [
2289 AC_MSG_CHECKING(for special defines needed for etip.h)
2290 cf_save_CXXFLAGS="$CXXFLAGS"
2291 cf_result="none"
2292
2293 # etip.h includes ncurses.h which includes ncurses_dll.h
2294 # But ncurses_dll.h is generated - fix here.
2295 test -d include || mkdir include
2296 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' "${srcdir}/include/ncurses_dll.h.in" >include/ncurses_dll.h
2297
2298 for cf_math in "" MATH_H
2299 do
2300 for cf_excp in "" MATH_EXCEPTION
2301 do
2302         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
2303         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
2304         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
2305 AC_TRY_COMPILE([
2306 #include <etip.h.in>
2307 ],[],[
2308         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
2309         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
2310         cf_result="$cf_math $cf_excp"
2311         break 2
2312 ],[])
2313 done
2314 done
2315 AC_MSG_RESULT($cf_result)
2316 CXXFLAGS="$cf_save_CXXFLAGS"
2317 ])
2318 dnl ---------------------------------------------------------------------------
2319 dnl CF_FIND_LINKAGE version: 22 updated: 2020/12/31 20:19:42
2320 dnl ---------------
2321 dnl Find a library (specifically the linkage used in the code fragment),
2322 dnl searching for it if it is not already in the library path.
2323 dnl See also CF_ADD_SEARCHPATH.
2324 dnl
2325 dnl Parameters (4-on are optional):
2326 dnl     $1 = headers for library entrypoint
2327 dnl     $2 = code fragment for library entrypoint
2328 dnl     $3 = the library name without the "-l" option or ".so" suffix.
2329 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
2330 dnl     $5 = action to perform if not successful
2331 dnl     $6 = module name, if not the same as the library name
2332 dnl     $7 = extra libraries
2333 dnl
2334 dnl Sets these variables:
2335 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
2336 dnl     $cf_cv_header_path_$3 - include-directory if needed
2337 dnl     $cf_cv_library_path_$3 - library-directory if needed
2338 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
2339 AC_DEFUN([CF_FIND_LINKAGE],[
2340
2341 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
2342 # will be set on completion of the AC_TRY_LINK below.
2343 cf_cv_header_path_$3=
2344 cf_cv_library_path_$3=
2345
2346 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
2347
2348 cf_save_LIBS="$LIBS"
2349
2350 AC_TRY_LINK([$1],[$2],[
2351         cf_cv_find_linkage_$3=yes
2352         cf_cv_header_path_$3=/usr/include
2353         cf_cv_library_path_$3=/usr/lib
2354 ],[
2355
2356 LIBS="-l$3 $7 $cf_save_LIBS"
2357
2358 AC_TRY_LINK([$1],[$2],[
2359         cf_cv_find_linkage_$3=yes
2360         cf_cv_header_path_$3=/usr/include
2361         cf_cv_library_path_$3=/usr/lib
2362         cf_cv_library_file_$3="-l$3"
2363 ],[
2364         cf_cv_find_linkage_$3=no
2365         LIBS="$cf_save_LIBS"
2366
2367         CF_VERBOSE(find linkage for $3 library)
2368         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
2369
2370         cf_save_CPPFLAGS="$CPPFLAGS"
2371         cf_test_CPPFLAGS="$CPPFLAGS"
2372
2373         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
2374         for cf_cv_header_path_$3 in $cf_search
2375         do
2376                 if test -d "$cf_cv_header_path_$3" ; then
2377                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
2378                         CPPFLAGS="$cf_save_CPPFLAGS"
2379                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
2380                         AC_TRY_COMPILE([$1],[$2],[
2381                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
2382                                 cf_cv_find_linkage_$3=maybe
2383                                 cf_test_CPPFLAGS="$CPPFLAGS"
2384                                 break],[
2385                                 CPPFLAGS="$cf_save_CPPFLAGS"
2386                                 ])
2387                 fi
2388         done
2389
2390         if test "$cf_cv_find_linkage_$3" = maybe ; then
2391
2392                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
2393
2394                 cf_save_LIBS="$LIBS"
2395                 cf_save_LDFLAGS="$LDFLAGS"
2396
2397                 ifelse([$6],,,[
2398                 CPPFLAGS="$cf_test_CPPFLAGS"
2399                 LIBS="-l$3 $7 $cf_save_LIBS"
2400                 AC_TRY_LINK([$1],[$2],[
2401                         CF_VERBOSE(... found $3 library in system)
2402                         cf_cv_find_linkage_$3=yes])
2403                         CPPFLAGS="$cf_save_CPPFLAGS"
2404                         LIBS="$cf_save_LIBS"
2405                         ])
2406
2407                 if test "$cf_cv_find_linkage_$3" != yes ; then
2408                         CF_LIBRARY_PATH(cf_search,$3)
2409                         for cf_cv_library_path_$3 in $cf_search
2410                         do
2411                                 if test -d "$cf_cv_library_path_$3" ; then
2412                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
2413                                         CPPFLAGS="$cf_test_CPPFLAGS"
2414                                         LIBS="-l$3 $7 $cf_save_LIBS"
2415                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
2416                                         AC_TRY_LINK([$1],[$2],[
2417                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
2418                                         cf_cv_find_linkage_$3=yes
2419                                         cf_cv_library_file_$3="-l$3"
2420                                         break],[
2421                                         CPPFLAGS="$cf_save_CPPFLAGS"
2422                                         LIBS="$cf_save_LIBS"
2423                                         LDFLAGS="$cf_save_LDFLAGS"
2424                                         ])
2425                                 fi
2426                         done
2427                         CPPFLAGS="$cf_save_CPPFLAGS"
2428                         LDFLAGS="$cf_save_LDFLAGS"
2429                 fi
2430
2431         else
2432                 cf_cv_find_linkage_$3=no
2433         fi
2434         ],$7)
2435 ])
2436
2437 LIBS="$cf_save_LIBS"
2438
2439 if test "$cf_cv_find_linkage_$3" = yes ; then
2440 ifelse([$4],,[
2441         CF_ADD_INCDIR($cf_cv_header_path_$3)
2442         CF_ADD_LIBDIR($cf_cv_library_path_$3)
2443         CF_ADD_LIB($3)
2444 ],[$4])
2445 else
2446 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
2447 fi
2448 ])dnl
2449 dnl ---------------------------------------------------------------------------
2450 dnl CF_FIND_SUB_INCDIR version: 3 updated: 2021/01/01 13:31:04
2451 dnl ------------------
2452 dnl Find an include-directory with the given leaf-name.  This is useful for
2453 dnl example with FreeBSD ports, which use this convention to distinguish
2454 dnl different versions of the same port.
2455 AC_DEFUN([CF_FIND_SUB_INCDIR],[
2456         CF_SUBDIR_PATH(cf_search,$1,include)
2457         for cf_item in $cf_search
2458         do
2459                 case "$cf_item" in
2460                 (*/$1)
2461                         CF_ADD_INCDIR($cf_item)
2462                         ;;
2463                 esac
2464         done
2465 ])dnl
2466 dnl ---------------------------------------------------------------------------
2467 dnl CF_FIND_SUB_LIBDIR version: 3 updated: 2021/01/01 13:31:04
2468 dnl ------------------
2469 dnl Find a library-directory with the given leaf-name.  This is useful for
2470 dnl example with FreeBSD ports, which use this convention to distinguish
2471 dnl different versions of the same port.
2472 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
2473         CF_SUBDIR_PATH(cf_search,$1,lib)
2474         for cf_item in $cf_search
2475         do
2476                 case "$cf_item" in
2477                 (*/$1)
2478                         CF_ADD_LIBDIR($cf_item)
2479                         ;;
2480                 esac
2481         done
2482 ])dnl
2483 dnl ---------------------------------------------------------------------------
2484 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
2485 dnl -----------------
2486 dnl make ADAFLAGS consistent with CFLAGS
2487 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
2488         AC_MSG_CHECKING(optimization options for ADAFLAGS)
2489         case "$CFLAGS" in
2490         (*-g*)
2491                 CF_ADD_ADAFLAGS(-g)
2492                 ;;
2493         esac
2494         case "$CFLAGS" in
2495         (*-O*)
2496                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
2497                 CF_ADD_ADAFLAGS($cf_O_flag)
2498                 ;;
2499         esac
2500         AC_MSG_RESULT($ADAFLAGS)
2501 ])dnl
2502 dnl ---------------------------------------------------------------------------
2503 dnl CF_FIX_WARNINGS version: 4 updated: 2021/12/16 18:22:31
2504 dnl ---------------
2505 dnl Warning flags do not belong in CFLAGS, CPPFLAGS, etc.  Any of gcc's
2506 dnl "-Werror" flags can interfere with configure-checks.  Those go into
2507 dnl EXTRA_CFLAGS.
2508 dnl
2509 dnl $1 = variable name to repair
2510 define([CF_FIX_WARNINGS],[
2511 if test "$GCC" = yes || test "$GXX" = yes
2512 then
2513         case [$]$1 in
2514         (*-Werror=*)
2515                 cf_temp_flags=
2516                 for cf_temp_scan in [$]$1
2517                 do
2518                         case "x$cf_temp_scan" in
2519                         (x-Werror=format*)
2520                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
2521                                 ;;
2522                         (x-Werror=*)
2523                                 CF_APPEND_TEXT(EXTRA_CFLAGS,$cf_temp_scan)
2524                                 ;;
2525                         (*)
2526                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
2527                                 ;;
2528                         esac
2529                 done
2530                 if test "x[$]$1" != "x$cf_temp_flags"
2531                 then
2532                         CF_VERBOSE(repairing $1: [$]$1)
2533                         $1="$cf_temp_flags"
2534                         CF_VERBOSE(... fixed [$]$1)
2535                         CF_VERBOSE(... extra $EXTRA_CFLAGS)
2536                 fi
2537                 ;;
2538         esac
2539 fi
2540 AC_SUBST(EXTRA_CFLAGS)
2541 ])dnl
2542 dnl ---------------------------------------------------------------------------
2543 dnl CF_FOPEN_BIN_R version: 2 updated: 2019/12/31 08:53:54
2544 dnl --------------
2545 dnl Check if fopen works when the "b" (binary) flag is added to the mode
2546 dnl parameter.  POSIX ignores the "b", which c89 specified.  Some very old
2547 dnl systems do not accept it.
2548 AC_DEFUN([CF_FOPEN_BIN_R],[
2549 AC_CACHE_CHECK(if fopen accepts explicit binary mode,cf_cv_fopen_bin_r,[
2550         AC_TRY_RUN([
2551 #include <stdio.h>
2552 int main(void) {
2553         FILE *fp = fopen("conftest.tmp", "wb");
2554         int rc = 0;
2555         if (fp != 0) {
2556                 int p, q;
2557                 for (p = 0; p < 256; ++p) {
2558                         fputc(p, fp);
2559                 }
2560                 fclose(fp);
2561                 fp = fopen("conftest.tmp", "rb");
2562                 if (fp != 0) {
2563                         for (p = 0; p < 256; ++p) {
2564                                 q = fgetc(fp);
2565                                 if (q != p) {
2566                                         rc = 1;
2567                                         break;
2568                                 }
2569                         }
2570                 } else {
2571                         rc = 1;
2572                 }
2573         } else {
2574                 rc = 1;
2575         }
2576         ${cf_cv_main_return:-return} (rc);
2577 }
2578 ],
2579                 [cf_cv_fopen_bin_r=yes],
2580                 [cf_cv_fopen_bin_r=no],
2581                 [cf_cv_fopen_bin_r=unknown])
2582 ])
2583 test "x$cf_cv_fopen_bin_r" != xno && AC_DEFINE(USE_FOPEN_BIN_R,1,[Define to 1 if fopen accepts explicit binary mode])
2584 ])dnl
2585 dnl ---------------------------------------------------------------------------
2586 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
2587 dnl --------------
2588 dnl Forget that we saw the given tool.
2589 AC_DEFUN([CF_FORGET_TOOL],[
2590 unset ac_cv_prog_ac_ct_$1
2591 unset ac_ct_$1
2592 unset $1
2593 ])dnl
2594 dnl ---------------------------------------------------------------------------
2595 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
2596 dnl -------------
2597 dnl Test for dlsym() and related functions, as well as libdl.
2598 dnl
2599 dnl Sets
2600 dnl     $cf_have_dlsym
2601 dnl     $cf_have_libdl
2602 AC_DEFUN([CF_FUNC_DLSYM],[
2603 cf_have_dlsym=no
2604 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
2605
2606 cf_have_libdl=no
2607 AC_CHECK_LIB(dl,dlsym,[
2608         cf_have_dlsym=yes
2609         cf_have_libdl=yes])])
2610
2611 if test "$cf_have_dlsym" = yes ; then
2612         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
2613
2614         AC_MSG_CHECKING(whether able to link to dl*() functions)
2615         AC_TRY_LINK([#include <dlfcn.h>],[
2616                 void *obj;
2617                 if ((obj = dlopen("filename", 0)) != 0) {
2618                         if (dlsym(obj, "symbolname") == 0) {
2619                         dlclose(obj);
2620                         }
2621                 }],[
2622                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
2623                 AC_MSG_ERROR(Cannot link test program for libdl)])
2624         AC_MSG_RESULT(ok)
2625 else
2626         AC_MSG_ERROR(Cannot find dlsym function)
2627 fi
2628 ])
2629 dnl ---------------------------------------------------------------------------
2630 dnl CF_FUNC_GETTTYNAM version: 1 updated: 2021/12/04 18:29:47
2631 dnl -----------------
2632 dnl Check if the 4.3BSD function getttyname exists, as well as if <ttyent.h>
2633 dnl defines the _PATH_TTYS symbol.  If the corresponding file exists, but the
2634 dnl other checks fail, just define HAVE_PATH_TTYS.
2635 AC_DEFUN([CF_FUNC_GETTTYNAM],[
2636 AC_CACHE_CHECK(if _PATH_TTYS is defined in ttyent.h,cf_cv_PATH_TTYS,[
2637 AC_TRY_COMPILE([
2638 #include <stdio.h>
2639 #include <ttyent.h>],[
2640 FILE *fp = fopen(_PATH_TTYS, "r"); (void)fp],
2641         [cf_cv_PATH_TTYS=yes],
2642         [cf_cv_PATH_TTYS=no])])
2643
2644 if test $cf_cv_PATH_TTYS = no
2645 then
2646         for cf_ttys in /etc/ttytype /etc/ttys
2647         do
2648                 if test -f $cf_ttys
2649                 then
2650                         cf_cv_PATH_TTYS=maybe
2651                         AC_DEFINE(_PATH_TTYS,$cf_ttys,[define to pathname of file containing mapping from tty name to terminal type])
2652                         break
2653                 fi
2654         done
2655 fi
2656
2657 if test $cf_cv_PATH_TTYS != no
2658 then
2659         AC_CACHE_CHECK(if _PATH_TTYS file exists,cf_cv_have_PATH_TTYS,[
2660                 AC_TRY_RUN([
2661 #include <stdio.h>
2662 #include <ttyent.h>
2663 int main(void) {
2664         FILE *fp = fopen(_PATH_TTYS, "r");
2665         ${cf_cv_main_return:-return} (fp == 0);
2666 }],
2667                         [cf_cv_have_PATH_TTYS=yes],
2668                         [cf_cv_have_PATH_TTYS=no],
2669                         [cf_cv_have_PATH_TTYS=unknown])])
2670         test "$cf_cv_have_PATH_TTYS" = no && cf_cv_PATH_TTYS=no
2671 fi
2672
2673 if test $cf_cv_PATH_TTYS != no
2674 then
2675         AC_DEFINE(HAVE_PATH_TTYS,1,[define to 1 if system can map tty name to terminal type])
2676         AC_CACHE_CHECK(for getttynam,cf_cv_func_getttynam,[
2677                 AC_TRY_LINK([#include <ttyent.h>],
2678                 [struct ttyent *fp = getttynam("/dev/tty"); (void)fp],
2679                 [cf_cv_func_getttynam=yes],
2680                 [cf_cv_func_getttynam=no])])
2681         test "$cf_cv_func_getttynam" = yes && AC_DEFINE(HAVE_GETTTYNAM)
2682 fi
2683 ])dnl
2684 dnl ---------------------------------------------------------------------------
2685 dnl CF_FUNC_MEMMOVE version: 9 updated: 2017/01/21 11:06:25
2686 dnl ---------------
2687 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
2688 dnl is found, add our own version of memmove to the list of objects.
2689 AC_DEFUN([CF_FUNC_MEMMOVE],
2690 [
2691 AC_CHECK_FUNC(memmove,,[
2692 AC_CHECK_FUNC(bcopy,[
2693         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
2694                 AC_TRY_RUN([
2695 int main(void) {
2696         static char data[] = "abcdefghijklmnopqrstuwwxyz";
2697         char temp[40];
2698         bcopy(data, temp, sizeof(data));
2699         bcopy(temp+10, temp, 15);
2700         bcopy(temp+5, temp+15, 10);
2701         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
2702 }
2703                 ],
2704                 [cf_cv_good_bcopy=yes],
2705                 [cf_cv_good_bcopy=no],
2706                 [cf_cv_good_bcopy=unknown])
2707                 ])
2708         ],[cf_cv_good_bcopy=no])
2709         if test "$cf_cv_good_bcopy" = yes ; then
2710                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
2711         else
2712                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
2713         fi
2714 ])])dnl
2715 dnl ---------------------------------------------------------------------------
2716 dnl CF_FUNC_NANOSLEEP version: 5 updated: 2017/01/21 11:06:25
2717 dnl -----------------
2718 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
2719 dnl AIX 4.x, provide a non-working version.
2720 AC_DEFUN([CF_FUNC_NANOSLEEP],[
2721 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
2722 AC_TRY_RUN([
2723 #include <stdio.h>
2724 #include <errno.h>
2725 #include <time.h>
2726
2727 #ifdef HAVE_SYS_TIME_H
2728 #include <sys/time.h>
2729 #endif
2730
2731 int main(void) {
2732         struct timespec ts1, ts2;
2733         int code;
2734         ts1.tv_sec  = 0;
2735         ts1.tv_nsec = 750000000;
2736         ts2.tv_sec  = 0;
2737         ts2.tv_nsec = 0;
2738         errno = 0;
2739         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
2740         ${cf_cv_main_return:-return}(code != 0);
2741 }
2742 ],
2743         [cf_cv_func_nanosleep=yes],
2744         [cf_cv_func_nanosleep=no],
2745         [cf_cv_func_nanosleep=unknown])])
2746
2747 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
2748 ])
2749 dnl ---------------------------------------------------------------------------
2750 dnl CF_FUNC_OPENPTY version: 6 updated: 2021/01/01 13:31:04
2751 dnl ---------------
2752 dnl Check for openpty() function, along with <pty.h> header.  It may need the
2753 dnl "util" library as well.
2754 AC_DEFUN([CF_FUNC_OPENPTY],
2755 [
2756 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
2757 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
2758         cf_save_LIBS="$LIBS"
2759         test "$cf_cv_lib_util" = yes && { CF_ADD_LIB(util) }
2760         for cf_header in pty.h libutil.h util.h
2761         do
2762         AC_TRY_LINK([
2763 #include <$cf_header>
2764 ],[
2765         int x = openpty((int *)0, (int *)0, (char *)0,
2766                                    (struct termios *)0, (struct winsize *)0);
2767 ],[
2768                 cf_cv_func_openpty=$cf_header
2769                 break
2770 ],[
2771                 cf_cv_func_openpty=no
2772 ])
2773         done
2774         LIBS="$cf_save_LIBS"
2775 ])
2776 ])dnl
2777 dnl ---------------------------------------------------------------------------
2778 dnl CF_FUNC_POLL version: 10 updated: 2021/01/04 19:13:57
2779 dnl ------------
2780 dnl See if the poll function really works.  Some platforms have poll(), but
2781 dnl it does not work for terminals or files.
2782 AC_DEFUN([CF_FUNC_POLL],[
2783 tty >/dev/null 2>&1 || { AC_CHECK_FUNCS(posix_openpt) }
2784 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2785 AC_TRY_RUN([
2786 #include <stdlib.h>
2787 #include <stdio.h>
2788 #include <unistd.h>
2789 #include <fcntl.h>
2790 #ifdef HAVE_POLL_H
2791 #include <poll.h>
2792 #else
2793 #include <sys/poll.h>
2794 #endif
2795 int main(void) {
2796         struct pollfd myfds;
2797         int ret;
2798
2799         /* check for Darwin bug with respect to "devices" */
2800         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2801         if (myfds.fd < 0)
2802                 myfds.fd = 0;
2803         myfds.events = POLLIN;
2804         myfds.revents = 0;
2805
2806         ret = poll(&myfds, 1, 100);
2807
2808         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2809                 ret = -1;
2810         } else {
2811                 int fd = 0;
2812                 if (!isatty(fd)) {
2813                         fd = open("/dev/tty", 2);       /* O_RDWR */
2814                 }
2815 #ifdef HAVE_POSIX_OPENPT
2816                 if (fd < 0) {
2817                         fd = posix_openpt(O_RDWR);
2818                 }
2819 #endif
2820
2821                 if (fd >= 0) {
2822                         /* also check with standard input */
2823                         myfds.fd = fd;
2824                         myfds.events = POLLIN;
2825                         myfds.revents = 0;
2826                         ret = poll(&myfds, 1, 100);
2827                 } else {
2828                         ret = -1;
2829                 }
2830         }
2831         ${cf_cv_main_return:-return}(ret < 0);
2832 }],
2833         [cf_cv_working_poll=yes],
2834         [cf_cv_working_poll=no],
2835         [cf_cv_working_poll=unknown])])
2836 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2837 ])dnl
2838 dnl ---------------------------------------------------------------------------
2839 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2840 dnl ---------------
2841 dnl Some old/broken variations define tcgetattr() only as a macro in
2842 dnl termio(s).h
2843 AC_DEFUN([CF_FUNC_TERMIOS],[
2844 AC_REQUIRE([CF_STRUCT_TERMIOS])
2845 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2846 AC_TRY_LINK([
2847 #include <sys/types.h>
2848 #ifdef HAVE_UNISTD_H
2849 #include <unistd.h>
2850 #endif
2851 #ifdef HAVE_TERMIOS_H
2852 #include <termios.h>
2853 #define TTY struct termios
2854 #else
2855 #ifdef HAVE_TERMIO_H
2856 #include <termio.h>
2857 #define TTY struct termio
2858 #endif
2859 #endif
2860 ],[
2861 TTY foo;
2862 tcgetattr(1, &foo);],
2863 [cf_cv_have_tcgetattr=yes],
2864 [cf_cv_have_tcgetattr=no])])
2865 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2866 ])dnl
2867 dnl ---------------------------------------------------------------------------
2868 dnl CF_FUNC_VSSCANF version: 7 updated: 2021/01/01 13:31:04
2869 dnl ---------------
2870 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2871 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2872 dnl other functions.
2873 AC_DEFUN([CF_FUNC_VSSCANF],
2874 [
2875 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2876 AC_TRY_LINK([
2877 #include <stdarg.h>
2878 #include <stdio.h>],[
2879         va_list ap;
2880         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2881 AC_TRY_LINK([
2882 #include <stdarg.h>
2883 #include <stdio.h>],[
2884         FILE strbuf;
2885         char *str = "from";
2886
2887         strbuf._flag = _IOREAD;
2888         strbuf._ptr = strbuf._base = (unsigned char *) str;
2889         strbuf._cnt = strlen(str);
2890         strbuf._file = _NFILE;
2891         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2892 AC_TRY_LINK([
2893 #include <stdarg.h>
2894 #include <stdio.h>],[
2895         FILE strbuf;
2896         char *str = "from";
2897
2898         strbuf._flag = _IOREAD;
2899         strbuf._ptr = strbuf._base = (unsigned char *) str;
2900         strbuf._cnt = strlen(str);
2901         strbuf._file = _NFILE;
2902         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2903 cf_cv_func_vsscanf=no])])])])
2904
2905 case "$cf_cv_func_vsscanf" in
2906 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2907 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2908 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2909 esac
2910
2911 ])dnl
2912 dnl ---------------------------------------------------------------------------
2913 dnl CF_GCC_ATTRIBUTES version: 24 updated: 2021/03/20 12:00:25
2914 dnl -----------------
2915 dnl Test for availability of useful gcc __attribute__ directives to quiet
2916 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2917 dnl to documentation, unrecognized directives cause older compilers to barf.
2918 AC_DEFUN([CF_GCC_ATTRIBUTES],
2919 [AC_REQUIRE([AC_PROG_FGREP])dnl
2920 AC_REQUIRE([CF_C11_NORETURN])dnl
2921
2922 if test "$GCC" = yes || test "$GXX" = yes
2923 then
2924 cat > conftest.i <<EOF
2925 #ifndef GCC_PRINTF
2926 #define GCC_PRINTF 0
2927 #endif
2928 #ifndef GCC_SCANF
2929 #define GCC_SCANF 0
2930 #endif
2931 #ifndef GCC_NORETURN
2932 #define GCC_NORETURN /* nothing */
2933 #endif
2934 #ifndef GCC_UNUSED
2935 #define GCC_UNUSED /* nothing */
2936 #endif
2937 EOF
2938 if test "$GCC" = yes
2939 then
2940         AC_CHECKING([for $CC __attribute__ directives])
2941 cat > "conftest.$ac_ext" <<EOF
2942 #line __oline__ "${as_me:-configure}"
2943 #include "confdefs.h"
2944 #include "conftest.h"
2945 #include "conftest.i"
2946 #if     GCC_PRINTF
2947 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2948 #else
2949 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2950 #endif
2951 #if     GCC_SCANF
2952 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2953 #else
2954 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2955 #endif
2956 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2957 extern GCC_NORETURN void oops(char *,...) GCC_PRINTFLIKE(1,2);
2958 extern GCC_NORETURN void foo(void);
2959 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
2960 EOF
2961         cf_printf_attribute=no
2962         cf_scanf_attribute=no
2963         for cf_attribute in scanf printf unused noreturn
2964         do
2965                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2966                 cf_directive="__attribute__(($cf_attribute))"
2967                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2968
2969                 case "$cf_attribute" in
2970                 (printf)
2971                         cf_printf_attribute=yes
2972                         cat >conftest.h <<EOF
2973 #define GCC_$cf_ATTRIBUTE 1
2974 EOF
2975                         ;;
2976                 (scanf)
2977                         cf_scanf_attribute=yes
2978                         cat >conftest.h <<EOF
2979 #define GCC_$cf_ATTRIBUTE 1
2980 EOF
2981                         ;;
2982                 (*)
2983                         cat >conftest.h <<EOF
2984 #define GCC_$cf_ATTRIBUTE $cf_directive
2985 EOF
2986                         ;;
2987                 esac
2988
2989                 if AC_TRY_EVAL(ac_compile); then
2990                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2991                         cat conftest.h >>confdefs.h
2992                         case "$cf_attribute" in
2993                         (noreturn)
2994                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2995                                 ;;
2996                         (printf)
2997                                 cf_value='/* nothing */'
2998                                 if test "$cf_printf_attribute" != no ; then
2999                                         cf_value='__attribute__((format(printf,fmt,var)))'
3000                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
3001                                 fi
3002                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
3003                                 ;;
3004                         (scanf)
3005                                 cf_value='/* nothing */'
3006                                 if test "$cf_scanf_attribute" != no ; then
3007                                         cf_value='__attribute__((format(scanf,fmt,var)))'
3008                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
3009                                 fi
3010                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
3011                                 ;;
3012                         (unused)
3013                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
3014                                 ;;
3015                         esac
3016                 fi
3017         done
3018 else
3019         ${FGREP-fgrep} define conftest.i >>confdefs.h
3020 fi
3021 rm -rf ./conftest*
3022 fi
3023 ])dnl
3024 dnl ---------------------------------------------------------------------------
3025 dnl CF_GCC_VERSION version: 8 updated: 2019/09/07 13:38:36
3026 dnl --------------
3027 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
3028 dnl compatible), attempt to determine if icc/clang is actually used.
3029 AC_DEFUN([CF_GCC_VERSION],[
3030 AC_REQUIRE([AC_PROG_CC])
3031 GCC_VERSION=none
3032 if test "$GCC" = yes ; then
3033         AC_MSG_CHECKING(version of $CC)
3034         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
3035         test -z "$GCC_VERSION" && GCC_VERSION=unknown
3036         AC_MSG_RESULT($GCC_VERSION)
3037 fi
3038 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
3039 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
3040 ])dnl
3041 dnl ---------------------------------------------------------------------------
3042 dnl CF_GCC_WARNINGS version: 41 updated: 2021/01/01 16:53:59
3043 dnl ---------------
3044 dnl Check if the compiler supports useful warning options.  There's a few that
3045 dnl we don't use, simply because they're too noisy:
3046 dnl
3047 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
3048 dnl     -Winline (usually not worthwhile)
3049 dnl     -Wredundant-decls (system headers make this too noisy)
3050 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
3051 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
3052 dnl             is enabled for ncurses using "--enable-const".
3053 dnl     -pedantic
3054 dnl
3055 dnl Parameter:
3056 dnl     $1 is an optional list of gcc warning flags that a particular
3057 dnl             application might want to use, e.g., "no-unused" for
3058 dnl             -Wno-unused
3059 dnl Special:
3060 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
3061 dnl
3062 AC_DEFUN([CF_GCC_WARNINGS],
3063 [
3064 AC_REQUIRE([CF_GCC_VERSION])
3065 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
3066 cat > "conftest.$ac_ext" <<EOF
3067 #line __oline__ "${as_me:-configure}"
3068 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
3069 EOF
3070 if test "$INTEL_COMPILER" = yes
3071 then
3072 # The "-wdXXX" options suppress warnings:
3073 # remark #1419: external declaration in primary source file
3074 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3075 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
3076 # remark #193: zero used for undefined preprocessing identifier
3077 # remark #593: variable "curs_sb_left_arrow" was set but never used
3078 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
3079 # remark #869: parameter "tw" was never referenced
3080 # remark #981: operands are evaluated in unspecified order
3081 # warning #279: controlling expression is constant
3082
3083         AC_CHECKING([for $CC warning options])
3084         cf_save_CFLAGS="$CFLAGS"
3085         EXTRA_CFLAGS="$EXTRA_CFLAGS -Wall"
3086         for cf_opt in \
3087                 wd1419 \
3088                 wd1683 \
3089                 wd1684 \
3090                 wd193 \
3091                 wd593 \
3092                 wd279 \
3093                 wd810 \
3094                 wd869 \
3095                 wd981
3096         do
3097                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
3098                 if AC_TRY_EVAL(ac_compile); then
3099                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3100                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
3101                 fi
3102         done
3103         CFLAGS="$cf_save_CFLAGS"
3104 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
3105 then
3106         AC_CHECKING([for $CC warning options])
3107         cf_save_CFLAGS="$CFLAGS"
3108         cf_warn_CONST=""
3109         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
3110         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
3111         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
3112         for cf_opt in W Wall \
3113                 Wbad-function-cast \
3114                 Wcast-align \
3115                 Wcast-qual \
3116                 Wdeclaration-after-statement \
3117                 Wextra \
3118                 Winline \
3119                 Wmissing-declarations \
3120                 Wmissing-prototypes \
3121                 Wnested-externs \
3122                 Wpointer-arith \
3123                 Wshadow \
3124                 Wstrict-prototypes \
3125                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
3126         do
3127                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
3128                 if AC_TRY_EVAL(ac_compile); then
3129                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3130                         case "$cf_opt" in
3131                         (Winline)
3132                                 case "$GCC_VERSION" in
3133                                 ([[34]].*)
3134                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
3135                                         continue;;
3136                                 esac
3137                                 ;;
3138                         (Wpointer-arith)
3139                                 case "$GCC_VERSION" in
3140                                 ([[12]].*)
3141                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
3142                                         continue;;
3143                                 esac
3144                                 ;;
3145                         esac
3146                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
3147                 fi
3148         done
3149         CFLAGS="$cf_save_CFLAGS"
3150 fi
3151 rm -rf ./conftest*
3152
3153 AC_SUBST(EXTRA_CFLAGS)
3154 ])dnl
3155 dnl ---------------------------------------------------------------------------
3156 dnl CF_GETOPT_HEADER version: 8 updated: 2021/06/19 19:16:16
3157 dnl ----------------
3158 dnl Check for getopt's variables which are commonly defined in stdlib.h,
3159 dnl unistd.h or (nonstandard) in getopt.h
3160 AC_DEFUN([CF_GETOPT_HEADER],
3161 [
3162 AC_HAVE_HEADERS(unistd.h getopt.h)
3163 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
3164 cf_cv_getopt_header=none
3165 for cf_header in stdio.h stdlib.h unistd.h getopt.h
3166 do
3167 AC_TRY_COMPILE([
3168 #include <$cf_header>],
3169 [int x = optind; char *y = optarg; (void)x; (void)y],
3170 [cf_cv_getopt_header=$cf_header
3171  break])
3172 done
3173 ])
3174 if test "$cf_cv_getopt_header" != none ; then
3175         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
3176 fi
3177 if test "$cf_cv_getopt_header" = getopt.h ; then
3178         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
3179 fi
3180 ])dnl
3181 dnl ---------------------------------------------------------------------------
3182 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
3183 dnl -----------------
3184 AC_DEFUN([CF_GNATPREP_OPT_T],[
3185 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
3186 cf_cv_gnatprep_opt_t=no
3187 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
3188 ])
3189 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
3190 AC_SUBST(GNATPREP_OPTS)
3191 ])dnl
3192 dnl ---------------------------------------------------------------------------
3193 dnl CF_GNAT_GENERICS version: 7 updated: 2021/01/01 13:31:04
3194 dnl ----------------
3195 AC_DEFUN([CF_GNAT_GENERICS],
3196 [
3197 AC_REQUIRE([CF_GNAT_VERSION])
3198
3199 AC_MSG_CHECKING(if GNAT supports generics)
3200 case "$cf_cv_gnat_version" in
3201 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
3202         cf_gnat_generics=yes
3203         ;;
3204 (*)
3205         cf_gnat_generics=no
3206         ;;
3207 esac
3208 AC_MSG_RESULT($cf_gnat_generics)
3209
3210 if test "$cf_gnat_generics" = yes
3211 then
3212         cf_compile_generics=generics
3213         cf_generic_objects="\${GENOBJS}"
3214 else
3215         cf_compile_generics=
3216         cf_generic_objects=
3217 fi
3218
3219 AC_SUBST(cf_compile_generics)
3220 AC_SUBST(cf_generic_objects)
3221 ])dnl
3222 dnl ---------------------------------------------------------------------------
3223 dnl CF_GNAT_PROJECTS version: 13 updated: 2021/01/02 17:09:14
3224 dnl ----------------
3225 dnl GNAT projects are configured with ".gpr" project files.
3226 dnl GNAT libraries are a further development, using the project feature.
3227 AC_DEFUN([CF_GNAT_PROJECTS],
3228 [
3229 AC_REQUIRE([CF_GNAT_VERSION])
3230 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
3231
3232 cf_gnat_libraries=no
3233 cf_gnat_projects=no
3234
3235 if test "$enable_gnat_projects" != no ; then
3236 AC_MSG_CHECKING(if GNAT supports project files)
3237 case "$cf_cv_gnat_version" in
3238 (3.[[0-9]]*)
3239         ;;
3240 (*)
3241         case "$cf_cv_system_name" in
3242         (cygwin*|msys*)
3243                 ;;
3244         (*)
3245                 rm -rf ./conftest* ./*~conftest*
3246                 if mkdir conftest.src conftest.bin conftest.lib
3247                 then
3248                         cd conftest.src
3249                         rm -rf ./conftest* ./*~conftest*
3250                         cat >>library.gpr <<CF_EOF
3251 project Library is
3252   Kind := External ("LIB_KIND");
3253   for Library_Name use "ConfTest";
3254   for Object_Dir use ".";
3255   for Library_ALI_Dir use External("LIBRARY_DIR");
3256   for Library_Version use External ("SONAME");
3257   for Library_Kind use Kind;
3258   for Library_Dir use External("BUILD_DIR");
3259   Source_Dir := External ("SOURCE_DIR");
3260   for Source_Dirs use (Source_Dir);
3261 end Library;
3262 CF_EOF
3263                         cat >>confpackage.ads <<CF_EOF
3264 package ConfPackage is
3265    procedure conftest;
3266 end ConfPackage;
3267 CF_EOF
3268                         cat >>confpackage.adb <<CF_EOF
3269 with Text_IO;
3270 package body ConfPackage is
3271    procedure conftest is
3272    begin
3273       Text_IO.Put ("Hello World");
3274       Text_IO.New_Line;
3275    end conftest;
3276 end ConfPackage;
3277 CF_EOF
3278                         if ( "$cf_ada_make" $ADAFLAGS \
3279                                         -Plibrary.gpr \
3280                                         -XBUILD_DIR="`cd ../conftest.bin;pwd`" \
3281                                         -XLIBRARY_DIR="`cd ../conftest.lib;pwd`" \
3282                                         -XSOURCE_DIR="`pwd`" \
3283                                         -XSONAME=libConfTest.so.1 \
3284                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
3285                                 cf_gnat_projects=yes
3286                         fi
3287                         cd ..
3288                 fi
3289                 if test -f conftest.lib/confpackage.ali
3290                 then
3291                         cf_gnat_libraries=yes
3292                 fi
3293                 rm -rf ./conftest* ./*~conftest*
3294                 ;;
3295         esac
3296         ;;
3297 esac
3298 AC_MSG_RESULT($cf_gnat_projects)
3299 fi # enable_gnat_projects
3300
3301 if test "$cf_gnat_projects" = yes
3302 then
3303         AC_MSG_CHECKING(if GNAT supports libraries)
3304         AC_MSG_RESULT($cf_gnat_libraries)
3305 fi
3306
3307 USE_OLD_MAKERULES=""
3308 USE_GNAT_PROJECTS="#"
3309 USE_GNAT_MAKE_GPR="#"
3310 USE_GNAT_GPRBUILD="#"
3311
3312 if test "$cf_gnat_projects" = yes
3313 then
3314         USE_OLD_MAKERULES="#"
3315         USE_GNAT_PROJECTS=""
3316         if test "$cf_cv_VERSION_GPRBUILD" != no
3317         then
3318                 USE_GNAT_GPRBUILD=""
3319         elif test "$cf_cv_VERSION_GNATMAKE" != no
3320         then
3321                 USE_GNAT_MAKE_GPR=""
3322         else
3323                 AC_MSG_WARN(use old makefile rules since tools are missing)
3324         fi
3325 fi
3326
3327 if test "$cf_gnat_libraries" = yes
3328 then
3329         USE_GNAT_LIBRARIES=""
3330 else
3331         USE_GNAT_LIBRARIES="#"
3332 fi
3333
3334 AC_SUBST(USE_OLD_MAKERULES)
3335 AC_SUBST(USE_GNAT_PROJECTS)
3336 AC_SUBST(USE_GNAT_LIBRARIES)
3337 AC_SUBST(USE_GNAT_MAKE_GPR)
3338 AC_SUBST(USE_GNAT_GPRBUILD)
3339 ])dnl
3340 dnl ---------------------------------------------------------------------------
3341 dnl CF_GNAT_SIGINT version: 2 updated: 2021/01/01 13:31:04
3342 dnl --------------
3343 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
3344 dnl is noted that gnat may compile a tasking unit even for configurations which
3345 dnl fail at runtime.
3346 AC_DEFUN([CF_GNAT_SIGINT],[
3347 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
3348 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
3349
3350 package ConfTest is
3351
3352    pragma Warnings (Off);  --  the next pragma exists since 3.11p
3353    pragma Unreserve_All_Interrupts;
3354    pragma Warnings (On);
3355
3356    protected Process is
3357       procedure Stop;
3358       function Continue return Boolean;
3359       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
3360    private
3361       Done : Boolean := False;
3362    end Process;
3363
3364 end ConfTest;],
3365 [package body ConfTest is
3366    protected body Process is
3367       procedure Stop is
3368       begin
3369          Done := True;
3370       end Stop;
3371       function Continue return Boolean is
3372       begin
3373          return not Done;
3374       end Continue;
3375    end Process;
3376 end ConfTest;],
3377         [cf_cv_gnat_sigint=yes],
3378         [cf_cv_gnat_sigint=no])])
3379
3380 if test "$cf_cv_gnat_sigint" = yes ; then
3381         USE_GNAT_SIGINT=""
3382 else
3383         USE_GNAT_SIGINT="#"
3384 fi
3385 AC_SUBST(USE_GNAT_SIGINT)
3386 ])dnl
3387 dnl ---------------------------------------------------------------------------
3388 dnl CF_GNAT_TRY_LINK version: 4 updated: 2021/01/01 13:31:04
3389 dnl ----------------
3390 dnl Verify that a test program compiles/links with GNAT.
3391 dnl $cf_ada_make is set to the program that compiles/links
3392 dnl $ADAFLAGS may be set to the GNAT flags.
3393 dnl
3394 dnl $1 is the text of the spec
3395 dnl $2 is the text of the body
3396 dnl $3 is the shell command to execute if successful
3397 dnl $4 is the shell command to execute if not successful
3398 AC_DEFUN([CF_GNAT_TRY_LINK],
3399 [
3400 rm -rf ./conftest* ./*~conftest*
3401 cat >>conftest.ads <<CF_EOF
3402 $1
3403 CF_EOF
3404 cat >>conftest.adb <<CF_EOF
3405 $2
3406 CF_EOF
3407 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3408 ifelse($3,,      :,[      $3])
3409 ifelse($4,,,[else
3410    $4])
3411 fi
3412 rm -rf ./conftest* ./*~conftest*
3413 ])dnl
3414 dnl ---------------------------------------------------------------------------
3415 dnl CF_GNAT_TRY_RUN version: 6 updated: 2021/01/01 13:31:04
3416 dnl ---------------
3417 dnl Verify that a test program compiles and runs with GNAT
3418 dnl $cf_ada_make is set to the program that compiles/links
3419 dnl $ADAFLAGS may be set to the GNAT flags.
3420 dnl
3421 dnl $1 is the text of the spec
3422 dnl $2 is the text of the body
3423 dnl $3 is the shell command to execute if successful
3424 dnl $4 is the shell command to execute if not successful
3425 AC_DEFUN([CF_GNAT_TRY_RUN],
3426 [
3427 rm -rf ./conftest* ./*~conftest*
3428 cat >>conftest.ads <<CF_EOF
3429 $1
3430 CF_EOF
3431 cat >>conftest.adb <<CF_EOF
3432 $2
3433 CF_EOF
3434 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3435    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
3436 ifelse($3,,      :,[      $3])
3437 ifelse($4,,,[   else
3438       $4])
3439    fi
3440 ifelse($4,,,[else
3441    $4])
3442 fi
3443 rm -rf ./conftest* ./*~conftest*
3444 ])dnl
3445 dnl ---------------------------------------------------------------------------
3446 dnl CF_GNAT_VERSION version: 22 updated: 2019/12/31 08:53:54
3447 dnl ---------------
3448 dnl $1 = cache variable to update
3449 dnl $2 = program name
3450 dnl Verify version of GNAT or related tool
3451 AC_DEFUN([CF_GNAT_VERSION],
3452 [
3453 AC_CACHE_CHECK(for ifelse($2,,gnat,$2) version, cf_cv_gnat_version,[
3454 cf_cv_gnat_version=`ifelse($2,,${cf_ada_make:-gnatmake},$2) --version 2>&1 | \
3455         grep '[[0-9]].[[0-9]][[0-9]]*' |\
3456         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
3457 ])
3458 test -z "$cf_cv_gnat_version" && cf_cv_gnat_version=no
3459 ifelse($1,,,[eval $1=$cf_cv_gnat_version; unset cf_cv_gnat_version])
3460 ])dnl
3461 dnl ---------------------------------------------------------------------------
3462 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
3463 dnl -------------
3464 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
3465 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
3466 dnl (or misfeature) of glibc2, which breaks portability of many applications,
3467 dnl since it is interwoven with GNU extensions.
3468 dnl
3469 dnl Well, yes we could work around it...
3470 dnl
3471 dnl Parameters:
3472 dnl     $1 is the nominal value for _XOPEN_SOURCE
3473 AC_DEFUN([CF_GNU_SOURCE],
3474 [
3475 cf_gnu_xopen_source=ifelse($1,,500,$1)
3476
3477 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
3478 AC_TRY_COMPILE([#include <sys/types.h>],[
3479         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
3480                 return 0;
3481         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
3482                 return 0;
3483         #else
3484         #       error not GNU C library
3485         #endif],
3486         [cf_cv_gnu_library=yes],
3487         [cf_cv_gnu_library=no])
3488 ])
3489
3490 if test x$cf_cv_gnu_library = xyes; then
3491
3492         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
3493         # was changed to help a little.  newlib incorporated the change about 4
3494         # years later.
3495         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
3496                 cf_save="$CPPFLAGS"
3497                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3498                 AC_TRY_COMPILE([#include <sys/types.h>],[
3499                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
3500                                 return 0;
3501                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
3502                                 return 0;
3503                         #else
3504                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
3505                         #endif],
3506                         [cf_cv_gnu_library_219=yes],
3507                         [cf_cv_gnu_library_219=no])
3508                 CPPFLAGS="$cf_save"
3509         ])
3510
3511         if test "x$cf_cv_gnu_library_219" = xyes; then
3512                 cf_save="$CPPFLAGS"
3513                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
3514                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
3515                         AC_TRY_COMPILE([
3516                                 #include <limits.h>
3517                                 #include <sys/types.h>
3518                                 ],[
3519                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
3520                                         return 0;
3521                                 #else
3522                                 #       error GNU C library is too old
3523                                 #endif],
3524                                 [cf_cv_gnu_dftsrc_219=yes],
3525                                 [cf_cv_gnu_dftsrc_219=no])
3526                         ])
3527                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
3528         else
3529                 cf_cv_gnu_dftsrc_219=maybe
3530         fi
3531
3532         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
3533
3534                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
3535                 AC_TRY_COMPILE([#include <sys/types.h>],[
3536                         #ifndef _XOPEN_SOURCE
3537                         #error  expected _XOPEN_SOURCE to be defined
3538                         #endif],
3539                         [cf_cv_gnu_source=no],
3540                         [cf_save="$CPPFLAGS"
3541                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
3542                          AC_TRY_COMPILE([#include <sys/types.h>],[
3543                                 #ifdef _XOPEN_SOURCE
3544                                 #error  expected _XOPEN_SOURCE to be undefined
3545                                 #endif],
3546                                 [cf_cv_gnu_source=no],
3547                                 [cf_cv_gnu_source=yes])
3548                         CPPFLAGS="$cf_save"
3549                         ])
3550                 ])
3551
3552                 if test "$cf_cv_gnu_source" = yes
3553                 then
3554                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
3555                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
3556                         AC_TRY_COMPILE([#include <sys/types.h>],[
3557                                 #ifdef _DEFAULT_SOURCE
3558                                 #error  expected _DEFAULT_SOURCE to be undefined
3559                                 #endif],
3560                                 [cf_cv_default_source=no],
3561                                 [cf_cv_default_source=yes])
3562                         ])
3563                         if test "$cf_cv_default_source" = yes
3564                         then
3565                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3566                         fi
3567                 fi
3568         fi
3569
3570 fi
3571 ])dnl
3572 dnl ---------------------------------------------------------------------------
3573 dnl CF_GPP_LIBRARY version: 13 updated: 2021/01/01 13:31:04
3574 dnl --------------
3575 dnl If we're trying to use g++, test if libg++ is installed (a rather common
3576 dnl problem :-).  If we have the compiler but no library, we'll be able to
3577 dnl configure, but won't be able to build the c++ demo program.
3578 AC_DEFUN([CF_GPP_LIBRARY],
3579 [
3580 cf_cxx_library=unknown
3581 case "$cf_cv_system_name" in
3582 (os2*)
3583         cf_gpp_libname=gpp
3584         ;;
3585 (*)
3586         cf_gpp_libname=g++
3587         ;;
3588 esac
3589 if test "$GXX" = yes; then
3590         AC_MSG_CHECKING([for lib$cf_gpp_libname])
3591         cf_save="$LIBS"
3592         CF_ADD_LIB($cf_gpp_libname)
3593         AC_TRY_LINK([
3594 #include <$cf_gpp_libname/builtin.h>
3595         ],
3596         [two_arg_error_handler_t foo2 = lib_error_handler],
3597         [cf_cxx_library=yes
3598          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3599          if test "$cf_gpp_libname" = cpp ; then
3600             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
3601          else
3602             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
3603          fi],
3604         [AC_TRY_LINK([
3605 #include <builtin.h>
3606         ],
3607         [two_arg_error_handler_t foo2 = lib_error_handler],
3608         [cf_cxx_library=yes
3609          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3610          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
3611         [cf_cxx_library=no])])
3612         LIBS="$cf_save"
3613         AC_MSG_RESULT($cf_cxx_library)
3614 fi
3615 ])dnl
3616 dnl ---------------------------------------------------------------------------
3617 dnl CF_GXX_VERSION version: 8 updated: 2017/02/11 14:48:57
3618 dnl --------------
3619 dnl Check for version of g++
3620 AC_DEFUN([CF_GXX_VERSION],[
3621 AC_REQUIRE([AC_PROG_CPP])
3622 GXX_VERSION=none
3623 if test "$GXX" = yes; then
3624         AC_MSG_CHECKING(version of ${CXX:-g++})
3625         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
3626         if test -z "$GXX_VERSION"
3627         then
3628                 GXX_VERSION=unknown
3629                 GXX=no
3630         fi
3631         AC_MSG_RESULT($GXX_VERSION)
3632 fi
3633 ])dnl
3634 dnl ---------------------------------------------------------------------------
3635 dnl CF_GXX_WARNINGS version: 11 updated: 2021/01/08 16:50:55
3636 dnl ---------------
3637 dnl Check if the compiler supports useful warning options.
3638 dnl
3639 dnl Most of gcc's options apply to g++, except:
3640 dnl     -Wbad-function-cast
3641 dnl     -Wmissing-declarations
3642 dnl     -Wnested-externs
3643 dnl
3644 dnl Omit a few (for now):
3645 dnl     -Winline
3646 dnl
3647 dnl Parameter:
3648 dnl     $1 is an optional list of g++ warning flags that a particular
3649 dnl             application might want to use, e.g., "no-unused" for
3650 dnl             -Wno-unused
3651 dnl Special:
3652 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
3653 dnl
3654 AC_DEFUN([CF_GXX_WARNINGS],
3655 [
3656
3657 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
3658 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
3659
3660 AC_REQUIRE([CF_GXX_VERSION])
3661
3662 AC_LANG_SAVE
3663 AC_LANG_CPLUSPLUS
3664
3665 cat > conftest.$ac_ext <<EOF
3666 #line __oline__ "configure"
3667 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
3668 EOF
3669
3670 if test "$INTEL_CPLUSPLUS" = yes
3671 then
3672 # The "-wdXXX" options suppress warnings:
3673 # remark #1419: external declaration in primary source file
3674 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3675 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3676 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
3677 # remark #193: zero used for undefined preprocessing identifier
3678 # remark #593: variable "curs_sb_left_arrow" was set but never used
3679 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
3680 # remark #869: parameter "tw" was never referenced
3681 # remark #981: operands are evaluated in unspecified order
3682 # warning #269: invalid format string conversion
3683
3684         AC_CHECKING([for $CC warning options])
3685         cf_save_CXXFLAGS="$CXXFLAGS"
3686         EXTRA_CXXFLAGS="-Wall"
3687         for cf_opt in \
3688                 wd1419 \
3689                 wd1682 \
3690                 wd1683 \
3691                 wd1684 \
3692                 wd193 \
3693                 wd279 \
3694                 wd593 \
3695                 wd810 \
3696                 wd869 \
3697                 wd981
3698         do
3699                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
3700                 if AC_TRY_EVAL(ac_compile); then
3701                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3702                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3703                 fi
3704         done
3705         CXXFLAGS="$cf_save_CXXFLAGS"
3706
3707 elif test "$GXX" = yes
3708 then
3709         AC_CHECKING([for $CXX warning options])
3710         cf_save_CXXFLAGS="$CXXFLAGS"
3711         EXTRA_CXXFLAGS="-W -Wall"
3712         cf_gxx_extra_warnings=""
3713         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
3714         case "$GXX_VERSION" in
3715         ([[1-2]].*)
3716                 ;;
3717         (*)
3718                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
3719                 ;;
3720         esac
3721         for cf_opt in \
3722                 Wabi \
3723                 fabi-version=0 \
3724                 Wextra \
3725                 Wignored-qualifiers \
3726                 Wlogical-op \
3727                 Woverloaded-virtual \
3728                 Wsign-promo \
3729                 Wsynth \
3730                 Wold-style-cast \
3731                 Wcast-align \
3732                 Wcast-qual \
3733                 Wpointer-arith \
3734                 Wshadow \
3735                 Wundef $cf_gxx_extra_warnings $1
3736         do
3737                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
3738                 if AC_TRY_EVAL(ac_compile); then
3739                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3740                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3741                 else
3742                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
3743                 fi
3744         done
3745         CXXFLAGS="$cf_save_CXXFLAGS"
3746 fi
3747
3748 rm -rf ./conftest*
3749 AC_LANG_RESTORE
3750 AC_SUBST(EXTRA_CXXFLAGS)
3751 ])dnl
3752 dnl ---------------------------------------------------------------------------
3753 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
3754 dnl ------------
3755 dnl Look for an instance of the Berkeley hashed database.
3756 dnl
3757 dnl $1 = optional parameter, to specify install-prefix for the database.
3758 AC_DEFUN([CF_HASHED_DB],
3759 [
3760 ifelse([$1],,,[
3761 case $1 in
3762 (yes|*able*)
3763         ;;
3764 (*)
3765         if test -d "$1" ; then
3766                 CF_ADD_INCDIR($1/include)
3767                 CF_ADD_LIBDIR($1/lib)
3768         else
3769                 case "$1" in
3770                 (./*|../*|/*)
3771                         AC_MSG_WARN(no such directory $1)
3772                         ;;
3773                 (*)
3774                         CF_FIND_SUB_INCDIR($1)
3775                         CF_FIND_SUB_LIBDIR($1)
3776                         ;;
3777                 esac
3778         fi
3779 esac
3780 ])
3781 AC_CHECK_HEADER(db.h,[
3782 CF_HASHED_DB_VERSION
3783 if test "$cf_cv_hashed_db_version" = unknown ; then
3784         AC_MSG_ERROR(Cannot determine version of db)
3785 else
3786         CF_HASHED_DB_LIBS
3787         if test "$cf_cv_hashed_db_libs" = unknown ; then
3788                 AC_MSG_ERROR(Cannot determine library for db)
3789         elif test "$cf_cv_hashed_db_libs" != default ; then
3790                 CF_ADD_LIB($cf_cv_hashed_db_libs)
3791         fi
3792 fi
3793 ],[
3794         AC_MSG_ERROR(Cannot find db.h)
3795 ])
3796 ])dnl
3797 dnl ---------------------------------------------------------------------------
3798 dnl CF_HASHED_DB_LIBS version: 10 updated: 2021/01/02 17:09:14
3799 dnl -----------------
3800 dnl Given that we have the header and version for hashed database, find the
3801 dnl library information.
3802 AC_DEFUN([CF_HASHED_DB_LIBS],
3803 [
3804 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
3805 cf_cv_hashed_db_libs=unknown
3806 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
3807 do
3808         cf_save_libs="$LIBS"
3809         if test -n "$cf_db_libs"; then
3810                 CF_ADD_LIB($cf_db_libs)
3811         fi
3812         CF_MSG_LOG(checking for library $cf_db_libs)
3813         AC_TRY_LINK([
3814 $ac_includes_default
3815 #include <db.h>
3816 ],[
3817         char *path = "/tmp/foo";
3818 #ifdef DB_VERSION_MAJOR
3819 #if DB_VERSION_MAJOR >= 4
3820         DB *result = 0;
3821         db_create(&result, NULL, 0);
3822         result->open(result,
3823                 NULL,
3824                 path,
3825                 path,
3826                 DB_HASH,
3827                 DB_CREATE,
3828                 0644);
3829 #elif DB_VERSION_MAJOR >= 3
3830         DB *result = 0;
3831         db_create(&result, NULL, 0);
3832         result->open(result,
3833                 path,
3834                 path,
3835                 DB_HASH,
3836                 DB_CREATE,
3837                 0644);
3838 #elif DB_VERSION_MAJOR >= 2
3839         DB *result = 0;
3840         db_open(path,
3841                 DB_HASH,
3842                 DB_CREATE,
3843                 0644,
3844                 (DB_ENV *) 0,
3845                 (DB_INFO *) 0,
3846                 &result);
3847 #endif /* DB_VERSION_MAJOR */
3848 #else
3849         DB *result = dbopen(path,
3850                      2,
3851                      0644,
3852                      DB_HASH,
3853                      0);
3854 #endif
3855         ${cf_cv_main_return:-return}(result != 0)
3856 ],[
3857         if test -n "$cf_db_libs" ; then
3858                 cf_cv_hashed_db_libs=$cf_db_libs
3859         else
3860                 cf_cv_hashed_db_libs=default
3861         fi
3862         LIBS="$cf_save_libs"
3863         break
3864 ])
3865         LIBS="$cf_save_libs"
3866 done
3867 ])
3868 ])dnl
3869 dnl ---------------------------------------------------------------------------
3870 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3871 dnl --------------------
3872 dnl Given that we have the header file for hashed database, find the version
3873 dnl information.
3874 AC_DEFUN([CF_HASHED_DB_VERSION],
3875 [
3876 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3877 cf_cv_hashed_db_version=unknown
3878
3879 for cf_db_version in 1 2 3 4 5 6
3880 do
3881         CF_MSG_LOG(checking for db version $cf_db_version)
3882         AC_TRY_COMPILE([
3883 $ac_includes_default
3884 #include <db.h>
3885
3886 #ifdef DB_VERSION_MAJOR
3887         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3888 #if $cf_db_version == DB_VERSION_MAJOR
3889         /* ok */
3890 #else
3891         make an error
3892 #endif
3893 #else
3894 #if $cf_db_version == 1
3895         /* ok: assuming this is DB 1.8.5 */
3896 #else
3897         make an error
3898 #endif
3899 #endif
3900 ],[DBT *foo = 0],[
3901         cf_cv_hashed_db_version=$cf_db_version
3902         break
3903         ])
3904 done
3905 ])
3906 ])dnl
3907 dnl ---------------------------------------------------------------------------
3908 dnl CF_HEADER_PATH version: 15 updated: 2021/01/01 13:31:04
3909 dnl --------------
3910 dnl Construct a search-list of directories for a nonstandard header-file
3911 dnl
3912 dnl Parameters
3913 dnl     $1 = the variable to return as result
3914 dnl     $2 = the package name
3915 AC_DEFUN([CF_HEADER_PATH],
3916 [
3917 $1=
3918
3919 # collect the current set of include-directories from compiler flags
3920 cf_header_path_list=""
3921 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3922         for cf_header_path in $CPPFLAGS $CFLAGS
3923         do
3924                 case "$cf_header_path" in
3925                 (-I*)
3926                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3927                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3928                         cf_header_path_list="$cf_header_path_list [$]$1"
3929                         ;;
3930                 esac
3931         done
3932 fi
3933
3934 # add the variations for the package we are looking for
3935 CF_SUBDIR_PATH($1,$2,include)
3936
3937 test "$includedir" != NONE && \
3938 test "$includedir" != "/usr/include" && \
3939 test -d "$includedir" && {
3940         test -d "$includedir" &&    $1="[$]$1 $includedir"
3941         test -d "$includedir/$2" && $1="[$]$1 $includedir/$2"
3942 }
3943
3944 test "$oldincludedir" != NONE && \
3945 test "$oldincludedir" != "/usr/include" && \
3946 test -d "$oldincludedir" && {
3947         test -d "$oldincludedir"    && $1="[$]$1 $oldincludedir"
3948         test -d "$oldincludedir/$2" && $1="[$]$1 $oldincludedir/$2"
3949 }
3950
3951 $1="[$]$1 $cf_header_path_list"
3952 ])dnl
3953 dnl ---------------------------------------------------------------------------
3954 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
3955 dnl ---------------
3956 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3957 AC_DEFUN([CF_HELP_MESSAGE],
3958 [CF_ACVERSION_CHECK(2.53,[],[
3959 AC_DIVERT_HELP($1)])dnl
3960 ])dnl
3961 dnl ---------------------------------------------------------------------------
3962 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3963 dnl ---------------
3964 dnl Construct the list of include-options according to whether we're building
3965 dnl in the source directory or using '--srcdir=DIR' option.
3966 AC_DEFUN([CF_INCLUDE_DIRS],
3967 [
3968 if test "$srcdir" != "."; then
3969         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3970 fi
3971 CPPFLAGS="-I../include $CPPFLAGS"
3972 if test "$srcdir" != "."; then
3973         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3974 fi
3975 CPPFLAGS="-I. $CPPFLAGS"
3976 AC_SUBST(CPPFLAGS)
3977 ])dnl
3978 dnl ---------------------------------------------------------------------------
3979 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
3980 dnl ---------------
3981 dnl prompt for/fill-in useful install-program options
3982 AC_DEFUN([CF_INSTALL_OPTS],
3983 [
3984 CF_INSTALL_OPT_S
3985 CF_INSTALL_OPT_P
3986 CF_INSTALL_OPT_O
3987 ])dnl
3988 dnl ---------------------------------------------------------------------------
3989 dnl CF_INSTALL_OPT_O version: 3 updated: 2020/12/31 20:19:42
3990 dnl ----------------
3991 dnl Almost all "install" programs default to the current user's ownership.
3992 dnl Almost - MINIX is an exception.
3993 AC_DEFUN([CF_INSTALL_OPT_O],
3994 [
3995 AC_MSG_CHECKING(if install needs to be told about ownership)
3996 case `$ac_config_guess` in
3997 (*minix)
3998         with_install_o=yes
3999         ;;
4000 (*)
4001         with_install_o=no
4002         ;;
4003 esac
4004
4005 AC_MSG_RESULT($with_install_o)
4006 if test "x$with_install_o" = xyes
4007 then
4008         INSTALL_OPT_O="`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`"
4009 else
4010         INSTALL_OPT_O=
4011 fi
4012
4013 AC_SUBST(INSTALL_OPT_O)
4014 ])dnl
4015 dnl ---------------------------------------------------------------------------
4016 dnl CF_INSTALL_OPT_P version: 3 updated: 2021/01/01 13:31:04
4017 dnl ----------------
4018 dnl Some install-programs accept a "-p" option to preserve file modification
4019 dnl timestamps.  That can be useful as an install option, as well as a way to
4020 dnl avoid the need for ranlib after copying a static archive.
4021 AC_DEFUN([CF_INSTALL_OPT_P],
4022 [
4023 : "${INSTALL:=install}"
4024 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
4025         rm -rf ./conftest*
4026         date >conftest.in
4027         mkdir conftest.out
4028         sleep 3
4029         if $INSTALL -p conftest.in conftest.out 2>/dev/null
4030         then
4031                 if test -f conftest.out/conftest.in
4032                 then
4033                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
4034                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
4035                         if test -s conftest.err
4036                         then
4037                                 cf_cv_install_p=no
4038                         else
4039                                 cf_cv_install_p=yes
4040                         fi
4041                 else
4042                         cf_cv_install_p=no
4043                 fi
4044         else
4045                 cf_cv_install_p=no
4046         fi
4047         rm -rf ./conftest*
4048 ])
4049 ])dnl
4050 dnl ---------------------------------------------------------------------------
4051 dnl CF_INSTALL_OPT_S version: 3 updated: 2021/01/05 19:23:48
4052 dnl ----------------
4053 dnl By default, we should strip executables which are installed, but leave the
4054 dnl ability to suppress that for unit-testing.
4055 AC_DEFUN([CF_INSTALL_OPT_S],
4056 [
4057 AC_MSG_CHECKING(if you want to install stripped executables)
4058 CF_ARG_DISABLE(stripping,
4059         [  --disable-stripping     do not strip (debug info) installed executables],
4060         [enable_stripping=no],
4061         [enable_stripping=yes])
4062 AC_MSG_RESULT($enable_stripping)
4063
4064 if test "$enable_stripping" = yes
4065 then
4066         INSTALL_OPT_S="-s"
4067 else
4068         INSTALL_OPT_S=
4069 fi
4070 AC_SUBST(INSTALL_OPT_S)
4071 ])dnl
4072 dnl ---------------------------------------------------------------------------
4073 dnl CF_INTEL_COMPILER version: 8 updated: 2021/01/01 16:53:59
4074 dnl -----------------
4075 dnl Check if the given compiler is really the Intel compiler for Linux.  It
4076 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
4077 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
4078 dnl
4079 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
4080 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
4081 dnl the wrappers for gcc and g++ warnings.
4082 dnl
4083 dnl $1 = GCC (default) or GXX
4084 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
4085 dnl $3 = CFLAGS (default) or CXXFLAGS
4086 AC_DEFUN([CF_INTEL_COMPILER],[
4087 AC_REQUIRE([AC_CANONICAL_HOST])
4088 ifelse([$2],,INTEL_COMPILER,[$2])=no
4089
4090 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
4091         case "$host_os" in
4092         (linux*|gnu*)
4093                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
4094                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
4095                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
4096                 AC_TRY_COMPILE([],[
4097 #ifdef __INTEL_COMPILER
4098 #else
4099 make an error
4100 #endif
4101 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
4102 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
4103 ],[])
4104                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
4105                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
4106                 ;;
4107         esac
4108 fi
4109 ])dnl
4110 dnl ---------------------------------------------------------------------------
4111 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
4112 dnl ----------
4113 dnl Check if we have either a function or macro for 'isascii()'.
4114 AC_DEFUN([CF_ISASCII],
4115 [
4116 AC_MSG_CHECKING(for isascii)
4117 AC_CACHE_VAL(cf_cv_have_isascii,[
4118         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
4119         [cf_cv_have_isascii=yes],
4120         [cf_cv_have_isascii=no])
4121 ])dnl
4122 AC_MSG_RESULT($cf_cv_have_isascii)
4123 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
4124 ])dnl
4125 dnl ---------------------------------------------------------------------------
4126 dnl CF_LARGEFILE version: 12 updated: 2020/03/19 20:23:48
4127 dnl ------------
4128 dnl Add checks for large file support.
4129 AC_DEFUN([CF_LARGEFILE],[
4130 ifdef([AC_FUNC_FSEEKO],[
4131         AC_SYS_LARGEFILE
4132         if test "$enable_largefile" != no ; then
4133         AC_FUNC_FSEEKO
4134
4135         # Normally we would collect these definitions in the config.h,
4136         # but (like _XOPEN_SOURCE), some environments rely on having these
4137         # defined before any of the system headers are included.  Another
4138         # case comes up with C++, e.g., on AIX the compiler compiles the
4139         # header files by themselves before looking at the body files it is
4140         # told to compile.  For ncurses, those header files do not include
4141         # the config.h
4142         if test "$ac_cv_sys_large_files" != no
4143         then
4144                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
4145         fi
4146         if test "$ac_cv_sys_largefile_source" != no
4147         then
4148                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
4149         fi
4150         if test "$ac_cv_sys_file_offset_bits" != no
4151         then
4152                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
4153         fi
4154
4155         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
4156                 AC_TRY_COMPILE([
4157 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
4158 #include <sys/types.h>
4159 #include <dirent.h>
4160                 ],[
4161                 /* if transitional largefile support is setup, this is true */
4162                 extern struct dirent64 * readdir(DIR *);
4163                 struct dirent64 *x = readdir((DIR *)0);
4164                 struct dirent *y = readdir((DIR *)0);
4165                 int z = x - y;
4166                 (void)z;
4167                 ],
4168                 [cf_cv_struct_dirent64=yes],
4169                 [cf_cv_struct_dirent64=no])
4170         ])
4171         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
4172         fi
4173 ])
4174 ])
4175 dnl ---------------------------------------------------------------------------
4176 dnl CF_LDFLAGS_STATIC version: 14 updated: 2021/01/02 17:09:14
4177 dnl -----------------
4178 dnl Check for compiler/linker flags used to temporarily force usage of static
4179 dnl libraries.  This depends on the compiler and platform.  Use this to help
4180 dnl ensure that the linker picks up a given library based on its position in
4181 dnl the list of linker options and libraries.
4182 AC_DEFUN([CF_LDFLAGS_STATIC],[
4183
4184 if test "$GCC" = yes ; then
4185         case "$cf_cv_system_name" in
4186         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
4187                 LDFLAGS_STATIC=
4188                 LDFLAGS_SHARED=
4189                 ;;
4190         (*)     # normally, except when broken
4191                 LDFLAGS_STATIC=-static
4192                 LDFLAGS_SHARED=-dynamic
4193                 ;;
4194         esac
4195 else
4196         case "$cf_cv_system_name" in
4197         (aix[[4-7]]*)   # from ld manpage
4198                 LDFLAGS_STATIC=-bstatic
4199                 LDFLAGS_SHARED=-bdynamic
4200                 ;;
4201         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
4202                 # We could also use just "archive" and "shared".
4203                 LDFLAGS_STATIC=-Wl,-a,archive_shared
4204                 LDFLAGS_SHARED=-Wl,-a,shared_archive
4205                 ;;
4206         (irix*)         # from ld manpage IRIX64
4207                 LDFLAGS_STATIC=-Bstatic
4208                 LDFLAGS_SHARED=-Bdynamic
4209                 ;;
4210         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
4211                 # alternative "-oldstyle_liblookup" (not in cc manpage)
4212                 LDFLAGS_STATIC=-noso
4213                 LDFLAGS_SHARED=-so_archive
4214                 ;;
4215         (solaris2*)
4216                 LDFLAGS_STATIC=-Bstatic
4217                 LDFLAGS_SHARED=-Bdynamic
4218                 ;;
4219         esac
4220 fi
4221
4222 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
4223 then
4224         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
4225
4226         rm -f libconftest.a
4227         cat >conftest.$ac_ext <<EOF
4228 #line __oline__ "configure"
4229 #include <stdio.h>
4230 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
4231 EOF
4232         if AC_TRY_EVAL(ac_compile) ; then
4233                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
4234                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
4235         fi
4236         rm -f conftest.*
4237
4238         cf_save_LIBS="$LIBS"
4239
4240         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
4241         AC_TRY_LINK([
4242 #line __oline__ "configure"
4243 #include <stdio.h>
4244 int cf_ldflags_static(FILE *fp);
4245 ],[
4246         return cf_ldflags_static(stdin);
4247 ],[
4248         # some linkers simply ignore the -dynamic
4249         case x`file "conftest$ac_exeext" 2>/dev/null` in
4250         (*static*)
4251                 cf_ldflags_static=no
4252                 ;;
4253         (*)
4254                 cf_ldflags_static=yes
4255                 ;;
4256         esac
4257 ],[cf_ldflags_static=no])
4258
4259         rm -f libconftest.*
4260         LIBS="$cf_save_LIBS"
4261
4262         AC_MSG_RESULT($cf_ldflags_static)
4263
4264         if test "$cf_ldflags_static" != yes
4265         then
4266                 LDFLAGS_STATIC=
4267                 LDFLAGS_SHARED=
4268         fi
4269 else
4270         LDFLAGS_STATIC=
4271         LDFLAGS_SHARED=
4272 fi
4273
4274 AC_SUBST(LDFLAGS_STATIC)
4275 AC_SUBST(LDFLAGS_SHARED)
4276 ])
4277 dnl ---------------------------------------------------------------------------
4278 dnl CF_LD_RPATH_OPT version: 9 updated: 2021/01/01 13:31:04
4279 dnl ---------------
4280 dnl For the given system and compiler, find the compiler flags to pass to the
4281 dnl loader to use the "rpath" feature.
4282 AC_DEFUN([CF_LD_RPATH_OPT],
4283 [
4284 AC_REQUIRE([CF_CHECK_CACHE])
4285
4286 LD_RPATH_OPT=
4287 if test "x$cf_cv_enable_rpath" != xno
4288 then
4289         AC_MSG_CHECKING(for an rpath option)
4290         case "$cf_cv_system_name" in
4291         (irix*)
4292                 if test "$GCC" = yes; then
4293                         LD_RPATH_OPT="-Wl,-rpath,"
4294                 else
4295                         LD_RPATH_OPT="-rpath "
4296                 fi
4297                 ;;
4298         (linux*|gnu*|k*bsd*-gnu|freebsd*)
4299                 LD_RPATH_OPT="-Wl,-rpath,"
4300                 ;;
4301         (openbsd[[2-9]].*|mirbsd*)
4302                 LD_RPATH_OPT="-Wl,-rpath,"
4303                 ;;
4304         (dragonfly*)
4305                 LD_RPATH_OPT="-rpath "
4306                 ;;
4307         (netbsd*)
4308                 LD_RPATH_OPT="-Wl,-rpath,"
4309                 ;;
4310         (osf*|mls+*)
4311                 LD_RPATH_OPT="-rpath "
4312                 ;;
4313         (solaris2*)
4314                 LD_RPATH_OPT="-R"
4315                 ;;
4316         (*)
4317                 ;;
4318         esac
4319         AC_MSG_RESULT($LD_RPATH_OPT)
4320
4321         case "x$LD_RPATH_OPT" in
4322         (x-R*)
4323                 AC_MSG_CHECKING(if we need a space after rpath option)
4324                 cf_save_LIBS="$LIBS"
4325                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
4326                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
4327                 LIBS="$cf_save_LIBS"
4328                 AC_MSG_RESULT($cf_rpath_space)
4329                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
4330                 ;;
4331         esac
4332 fi
4333 ])dnl
4334 dnl ---------------------------------------------------------------------------
4335 dnl CF_LD_SEARCHPATH version: 4 updated: 2022/08/27 15:43:08
4336 dnl ----------------
4337 dnl Try to obtain the linker's search-path, for use in scripts.
4338 dnl
4339 dnl Ignore LD_LIBRARY_PATH, etc.
4340 AC_DEFUN([CF_LD_SEARCHPATH],[
4341 AC_CACHE_CHECK(for linker search path,cf_cv_ld_searchpath,[
4342
4343 if test "$cross_compiling" != yes ; then
4344
4345 # GNU binutils' ld does not involve permissions which may stop ldconfig.
4346 cf_pathlist=`${LD:-ld} --verbose 2>/dev/null | grep SEARCH_DIR | sed -e 's,SEARCH_DIR[[("=]][[("=]]*,,g' -e 's/"[[)]];//gp' | sort -u`
4347
4348 # The -NX options tell newer versions of Linux ldconfig to not attempt to
4349 # update the cache, which makes it run faster.
4350 test -z "$cf_pathlist" && \
4351         cf_pathlist=`(ldconfig -NX -v) 2>/dev/null | sed -e '/^[[       ]]/d' -e 's/:$//' | sort -u`
4352
4353 test -z "$cf_pathlist" &&
4354         cf_pathlist=`(ldconfig -v) 2>/dev/null | sed -n -e '/^[[        ]]/d' -e 's/:$//p' | sort -u`
4355
4356 # This works with OpenBSD 6.5, which lists only filenames
4357 test -z "$cf_pathlist" &&
4358         cf_pathlist=`(ldconfig -v) 2>/dev/null | sed -n -e 's,^Adding \(.*\)/.*[$],\1,p' | sort -u`
4359
4360 if test -z "$cf_pathlist"
4361 then
4362         # dyld default path with MacOS
4363         if test -f /usr/bin/otool && test "x`uname -s`" = xDarwin
4364         then
4365                 # do this to bypass check
4366                 cf_cv_ld_searchpath='$HOME/lib'
4367                 cf_pathlist="/usr/local/lib /lib /usr/lib"
4368         fi
4369 fi
4370
4371 if test -z "$cf_pathlist"
4372 then
4373         # Solaris is "SunOS"
4374         if test -f /usr/bin/isainfo && test "x`uname -s`" = xSunOS
4375         then
4376                 case x`(isainfo -b)` in
4377                 (x64)
4378                         cf_pathlist="$cf_pathlist /lib/64 /usr/lib/64"
4379                         ;;
4380                 (x32)
4381                         test -d /usr/ccs/lib && cf_pathlist="$cf_pathlist /usr/ccs/lib"
4382                         cf_pathlist="$cf_pathlist /lib /usr/lib"
4383                         ;;
4384                 (*)
4385                         AC_MSG_WARN(problem with Solaris architecture)
4386                         ;;
4387                 esac
4388         fi
4389 fi
4390
4391 if test -z "$cf_pathlist"
4392 then
4393         # HP-UX
4394         if test x"`uname -s`" = xHP-UX
4395         then
4396                 case x`getconf LONG_BIT` in
4397                 (x64)
4398                         cf_pathlist="/usr/lib/hpux64"
4399                         ;;
4400                 (x*)
4401                         cf_pathlist="/usr/lib/hpux32"
4402                         ;;
4403                 esac
4404         fi
4405 fi
4406
4407 fi
4408
4409 # If nothing else, assume it is conventional
4410 test -z "$cf_pathlist" && cf_pathlist="/usr/lib /lib"
4411
4412 # Finally, check that this is only directories
4413 for cf_path in [$]0 $cf_pathlist
4414 do
4415         if test -d "$cf_path"; then
4416                 test -n "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath="${cf_cv_ld_searchpath} "
4417                 cf_cv_ld_searchpath="${cf_cv_ld_searchpath}${cf_path}"
4418         fi
4419 done
4420
4421 # Ensure that it is nonempty
4422 test -z "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath=/usr/lib
4423 ])
4424
4425 LD_SEARCHPATH=`echo "$cf_cv_ld_searchpath"|sed -e 's/ /|/g'`
4426 AC_SUBST(LD_SEARCHPATH)
4427 ])dnl
4428 dnl ---------------------------------------------------------------------------
4429 dnl CF_LIBRARY_PATH version: 11 updated: 2021/01/01 13:31:04
4430 dnl ---------------
4431 dnl Construct a search-list of directories for a nonstandard library-file
4432 dnl
4433 dnl Parameters
4434 dnl     $1 = the variable to return as result
4435 dnl     $2 = the package name
4436 AC_DEFUN([CF_LIBRARY_PATH],
4437 [
4438 $1=
4439 cf_library_path_list=""
4440 if test -n "${LDFLAGS}${LIBS}" ; then
4441         for cf_library_path in $LDFLAGS $LIBS
4442         do
4443                 case "$cf_library_path" in
4444                 (-L*)
4445                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
4446                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
4447                         cf_library_path_list="$cf_library_path_list [$]$1"
4448                         ;;
4449                 esac
4450         done
4451 fi
4452
4453 CF_SUBDIR_PATH($1,$2,lib)
4454
4455 $1="$cf_library_path_list [$]$1"
4456 ])dnl
4457 dnl ---------------------------------------------------------------------------
4458 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
4459 dnl ------------------
4460 AC_DEFUN([CF_LIBTOOL_VERSION],[
4461 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
4462 then
4463         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
4464 else
4465         cf_cv_libtool_version=
4466 fi
4467 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
4468 ])dnl
4469 dnl ---------------------------------------------------------------------------
4470 dnl CF_LIB_PREFIX version: 14 updated: 2021/01/01 13:31:04
4471 dnl -------------
4472 dnl Compute the library-prefix for the given host system
4473 dnl $1 = variable to set
4474 define([CF_LIB_PREFIX],
4475 [
4476         case "$cf_cv_system_name" in
4477         (OS/2*|os2*)
4478                 if test "$DFT_LWR_MODEL" = libtool; then
4479                         LIB_PREFIX='lib'
4480                 else
4481                         LIB_PREFIX=''
4482                 fi
4483                 ;;
4484         (*-msvc*)
4485                 LIB_PREFIX=''
4486                 ;;
4487         (*)     LIB_PREFIX='lib'
4488                 ;;
4489         esac
4490 ifelse($1,,,[$1=$LIB_PREFIX])
4491         AC_SUBST(LIB_PREFIX)
4492 ])dnl
4493 dnl ---------------------------------------------------------------------------
4494 dnl CF_LIB_RULES version: 97 updated: 2021/07/17 13:10:54
4495 dnl ------------
4496 dnl Append definitions and rules for the given models to the subdirectory
4497 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
4498 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
4499 dnl the corresponding makefile to list the models that we'll generate.
4500 dnl
4501 dnl For shared libraries, make a list of symbolic links to construct when
4502 dnl generating each library.  The convention used for Linux is the simplest
4503 dnl one:
4504 dnl     lib<name>.so    ->
4505 dnl     lib<name>.so.<major>    ->
4506 dnl     lib<name>.so.<maj>.<minor>
4507 dnl
4508 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
4509 AC_DEFUN([CF_LIB_RULES],
4510 [AC_REQUIRE([AC_PROG_FGREP])dnl
4511 AC_REQUIRE([CF_MAKE_PHONY])dnl
4512
4513 cf_prefix=$LIB_PREFIX
4514 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
4515
4516 case "$cf_cv_shlib_version" in
4517 (cygdll|msysdll|mingw|msvcdll)
4518         TINFO_NAME=$TINFO_ARG_SUFFIX
4519         TINFO_SUFFIX=.dll
4520         ;;
4521 esac
4522
4523 if test -n "$TINFO_SUFFIX" ; then
4524         case "$TINFO_SUFFIX" in
4525         (tw*)
4526                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
4527                 TINFO_SUFFIX=`echo "$TINFO_SUFFIX" | sed 's/^tw'$EXTRA_SUFFIX'//'`
4528                 ;;
4529         (t*)
4530                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
4531                 TINFO_SUFFIX=`echo "$TINFO_SUFFIX" | sed 's/^t'$EXTRA_SUFFIX'//'`
4532                 ;;
4533         (w*)
4534                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
4535                 TINFO_SUFFIX=`echo "$TINFO_SUFFIX" | sed 's/^w'$EXTRA_SUFFIX'//'`
4536                 ;;
4537         esac
4538 fi
4539
4540 for cf_dir in $SRC_SUBDIRS
4541 do
4542         if test ! -d "$srcdir/$cf_dir" ; then
4543                 continue
4544         elif test -f "$srcdir/$cf_dir/modules" ; then
4545
4546                 SHARED_LIB=
4547                 Libs_To_Make=
4548                 cf_awk_program=
4549                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
4550                 then
4551                         cf_awk_program="$cf_awk_program\
4552 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
4553 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
4554 "
4555                 fi
4556
4557                 if test "x$WILDCARD_SYMS" = xno
4558                 then
4559                         cf_awk_program="$cf_awk_program\
4560 /[[     ]]_\\*;/ { skip=1; next; }\
4561 "
4562                 fi
4563
4564                 if test "x$cf_awk_program" != "x"
4565                 then
4566                         cat >>$cf_dir/Makefile <<CF_EOF
4567
4568 # Generated by CF_LIB_RULES
4569 resulting.map: $UNALTERED_SYMS
4570         $AWK 'BEGIN { skip = 1; last=""; } \
4571 $cf_awk_program \
4572 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
4573  skip = 0; last = \[$]\[$]0; } \
4574 END { print last; }' < "$UNALTERED_SYMS" >\[$]@
4575
4576 distclean::
4577         rm -f resulting.map
4578 CF_EOF
4579                 fi
4580
4581                 for cf_item in $cf_LIST_MODELS
4582                 do
4583                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4584                         if test "$cf_dir" = "c++"
4585                         then
4586                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4587                         else
4588                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4589                         fi
4590                         test -z "$cf_libname" && cf_libname="$cf_dir"
4591                         if test "$cf_item" = shared ; then
4592                                 if test -n "${LIB_SUFFIX}"
4593                                 then
4594                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4595                                 else
4596                                         cf_shared_suffix="$cf_suffix"
4597                                 fi
4598                                 if test "$cf_cv_do_symlinks" = yes ; then
4599                                         cf_version_name=
4600
4601                                         case "$cf_cv_shlib_version" in
4602                                         (rel)
4603                                                 cf_version_name=REL_VERSION
4604                                                 ;;
4605                                         (abi)
4606                                                 cf_version_name=ABI_VERSION
4607                                                 ;;
4608                                         esac
4609
4610                                         if test -n "$cf_version_name"
4611                                         then
4612                                                 case "$cf_cv_system_name" in
4613                                                 (darwin*)
4614                                                         # "w", etc?
4615                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
4616                                                         ;;
4617                                                 (*)
4618                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
4619                                                         ;;
4620                                                 esac
4621                                         fi
4622                                         if test -n "${USE_LIB_SUFFIX}"
4623                                         then
4624                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4625                                         else
4626                                                 cf_shared_suffix="$cf_suffix"
4627                                         fi
4628                                 fi
4629                                 # cygwin needs import library, and has unique naming convention
4630                                 # use autodetected ${cf_prefix} for import lib and static lib, but
4631                                 # use 'cyg' prefix for shared lib.
4632                                 case "$cf_cv_shlib_version" in
4633                                 (cygdll)
4634                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4635                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
4636                                         ;;
4637                                 (msysdll)
4638                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4639                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
4640                                         ;;
4641                                 (mingw)
4642                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4643                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
4644                                         ;;
4645                                 (msvcdll)
4646                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4647                                         cf_add_lib="../lib/${cf_libname}${cf_cygsuf}"
4648                                         ;;
4649                                 (*)
4650                                         cf_add_lib=
4651                                         ;;
4652                                 esac
4653                                 if test -n "$cf_add_lib"
4654                                 then
4655                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4656                                         continue
4657                                 fi
4658                         fi
4659                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
4660                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4661                 done
4662
4663                 if test "$cf_dir" = ncurses ; then
4664                         cf_subsets="$LIB_SUBSETS"
4665                         cf_r_parts="$cf_subsets"
4666                         cf_liblist="$Libs_To_Make"
4667
4668                         while test -n "$cf_r_parts"
4669                         do
4670                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
4671                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
4672                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
4673                                         cf_add_lib=
4674                                         case "$cf_l_parts" in
4675                                         (*termlib*)
4676                                                 cf_add_lib=`echo "$cf_liblist" |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
4677                                                 ;;
4678                                         (*ticlib*)
4679                                                 cf_add_lib=`echo "$cf_liblist" |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
4680                                                 ;;
4681                                         (*)
4682                                                 break
4683                                                 ;;
4684                                         esac
4685                                         if test -n "$cf_add_lib"; then
4686                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
4687                                         fi
4688                                 else
4689                                         break
4690                                 fi
4691                         done
4692                 else
4693                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
4694                 fi
4695
4696                 if test "$cf_dir" = c++; then
4697                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
4698                                 cf_list=
4699                                 for cf_item in $Libs_To_Make
4700                                 do
4701                                         case "$cf_item" in
4702                                         (*.a)
4703                                                 ;;
4704                                         (*)
4705                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
4706                                                 ;;
4707                                         esac
4708                                         for cf_test in $cf_list
4709                                         do
4710                                                 if test "$cf_test" = "$cf_item"
4711                                                 then
4712                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
4713                                                         cf_item=
4714                                                         break
4715                                                 fi
4716                                         done
4717                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
4718                                 done
4719                                 Libs_To_Make="$cf_list"
4720                         fi
4721                 fi
4722
4723                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
4724                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
4725                         "$cf_dir/Makefile" >$cf_dir/Makefile.out
4726                 mv "$cf_dir/Makefile.out" "$cf_dir/Makefile"
4727
4728                 $AWK -f "$srcdir/mk-0th.awk" \
4729                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
4730                         "$srcdir/$cf_dir/modules" >>$cf_dir/Makefile
4731
4732                 for cf_subset in $cf_subsets
4733                 do
4734                         cf_subdirs=
4735                         for cf_item in $cf_LIST_MODELS
4736                         do
4737
4738                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
4739                         CF_UPPER(cf_ITEM,$cf_item)
4740
4741                         CXX_MODEL=$cf_ITEM
4742                         if test "$CXX_MODEL" = SHARED; then
4743                                 case "$cf_cv_shlib_version" in
4744                                 (cygdll|msysdll|mingw|msvcdll)
4745                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
4746                                         with_shared_cxx=yes
4747                                         ;;
4748                                 (*)
4749                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
4750                                         ;;
4751                                 esac
4752                         fi
4753
4754                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4755                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
4756
4757                         # Test for case where we build libtinfo with a different name.
4758                         cf_libname=$cf_dir
4759                         if test "$cf_dir" = ncurses ; then
4760                                 case "$cf_subset" in
4761                                 (*base*)
4762                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
4763                                         ;;
4764                                 (*termlib*)
4765                                         cf_libname=$TINFO_LIB_SUFFIX
4766                                         ;;
4767                                 (ticlib*)
4768                                         cf_libname=$TICS_LIB_SUFFIX
4769                                         ;;
4770                                 esac
4771                         elif test "$cf_dir" = c++ ; then
4772                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4773                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4774                         else
4775                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4776                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4777                         fi
4778                         if test -n "${USE_ARG_SUFFIX}" ; then
4779                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
4780                                 cf_suffix=`echo "$cf_suffix" |sed -e "s%^${USE_LIB_SUFFIX}%%"`
4781                         fi
4782
4783                         # These dependencies really are for development, not
4784                         # builds, but they are useful in porting, too.
4785                         cf_depend="../include/ncurses_cfg.h"
4786                         if test "$srcdir" = "."; then
4787                                 cf_reldir="."
4788                         else
4789                                 cf_reldir="\${srcdir}"
4790                         fi
4791
4792                         if test -f "$srcdir/$cf_dir/$cf_dir.priv.h" ; then
4793                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
4794                         elif test -f "$srcdir/$cf_dir/curses.priv.h" ; then
4795                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
4796                         fi
4797
4798                         cf_dir_suffix=
4799                         old_cf_suffix="$cf_suffix"
4800                         if test "$cf_cv_shlib_version_infix" = yes ; then
4801                         if test -n "$USE_LIB_SUFFIX" ; then
4802                                 case "$USE_LIB_SUFFIX" in
4803                                 (tw*)
4804                                         cf_libname=`echo "$cf_libname" | sed 's/tw'$EXTRA_SUFFIX'$//'`
4805                                         cf_suffix=`echo "$cf_suffix" | sed 's/^tw'$EXTRA_SUFFIX'//'`
4806                                         cf_dir_suffix=tw$EXTRA_SUFFIX
4807                                         ;;
4808                                 (t*)
4809                                         cf_libname=`echo "$cf_libname" | sed 's/t'$EXTRA_SUFFIX'$//'`
4810                                         cf_suffix=`echo "$cf_suffix" | sed 's/^t'$EXTRA_SUFFIX'//'`
4811                                         cf_dir_suffix=t$EXTRA_SUFFIX
4812                                         ;;
4813                                 (w*)
4814                                         cf_libname=`echo "$cf_libname" | sed 's/w'$EXTRA_SUFFIX'$//'`
4815                                         cf_suffix=`echo "$cf_suffix" | sed 's/^w'$EXTRA_SUFFIX'//'`
4816                                         cf_dir_suffix=w$EXTRA_SUFFIX
4817                                         ;;
4818                                 (*)
4819                                         cf_libname=`echo "$cf_libname" | sed 's/'$EXTRA_SUFFIX'$//'`
4820                                         cf_suffix=`echo "$cf_suffix" | sed 's/^'$EXTRA_SUFFIX'//'`
4821                                         cf_dir_suffix=$EXTRA_SUFFIX
4822                                         ;;
4823                                 esac
4824                         fi
4825                         fi
4826
4827                         $AWK -f "$srcdir/mk-1st.awk" \
4828                                 name=${cf_libname}${cf_dir_suffix} \
4829                                 traces=$LIB_TRACING \
4830                                 MODEL=$cf_ITEM \
4831                                 CXX_MODEL=$CXX_MODEL \
4832                                 LIB_SUFFIX=$LIB_SUFFIX \
4833                                 USE_LIB_SUFFIX=$USE_LIB_SUFFIX \
4834                                 make_phony="${cf_cv_make_PHONY:-no}" \
4835                                 model=$cf_subdir \
4836                                 prefix=$cf_prefix \
4837                                 suffix=$cf_suffix \
4838                                 subset=$cf_subset \
4839                                 driver=$cf_cv_term_driver \
4840                                 SymLink="$LN_S" \
4841                                 TermlibRoot=$TINFO_NAME \
4842                                 TermlibSuffix=$TINFO_SUFFIX \
4843                                 ShlibVer=$cf_cv_shlib_version \
4844                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
4845                                 ReLink=${cf_cv_do_relink:-no} \
4846                                 ReRanlib=${cf_cv_do_reranlib:-yes} \
4847                                 DoLinks=$cf_cv_do_symlinks \
4848                                 rmSoLocs=$cf_cv_rm_so_locs \
4849                                 ldconfig="$LDCONFIG" \
4850                                 overwrite=$WITH_OVERWRITE \
4851                                 depend="$cf_depend" \
4852                                 host="$host" \
4853                                 libtool_version="$LIBTOOL_VERSION" \
4854                                 "$srcdir/$cf_dir/modules" >>$cf_dir/Makefile
4855
4856                         cf_suffix="$old_cf_suffix"
4857
4858                         for cf_subdir2 in $cf_subdirs lib
4859                         do
4860                                 test "$cf_subdir" = "$cf_subdir2" && break
4861                         done
4862                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
4863                         $AWK -f "$srcdir/mk-2nd.awk" \
4864                                 name=$cf_dir \
4865                                 traces=$LIB_TRACING \
4866                                 MODEL=$cf_ITEM \
4867                                 model=$cf_subdir \
4868                                 subset=$cf_subset \
4869                                 srcdir=$srcdir \
4870                                 echo=$WITH_ECHO \
4871                                 crenames=$cf_cv_prog_CC_c_o \
4872                                 cxxrenames=$cf_cv_prog_CXX_c_o \
4873                                 "$srcdir/$cf_dir/modules" >>$cf_dir/Makefile
4874                         cf_subdirs="$cf_subdirs $cf_subdir"
4875                         done
4876                 done
4877         fi
4878
4879         echo '  ( cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@ )' >>Makefile
4880 done
4881
4882 echo >> Makefile
4883 echo '# generated by CF_LIB_RULES' >> Makefile
4884
4885 if test "x$cf_cv_make_PHONY" = xyes ; then
4886         cat >> Makefile <<-CF_EOF
4887
4888         .PHONY :        libs
4889         .PHONY :        lintlib
4890         .PHONY :        install.includes
4891         .PHONY :        uninstall.includes
4892         .PHONY :        install.libs
4893         .PHONY :        uninstall.libs
4894 CF_EOF
4895 fi
4896
4897 for cf_dir in $SRC_SUBDIRS
4898 do
4899         if test ! -d "$srcdir/$cf_dir" ; then
4900                 continue
4901         fi
4902
4903         if test -f "$cf_dir/Makefile" ; then
4904                 case "$cf_dir" in
4905                 (Ada95)
4906                         echo 'libs \' >> Makefile
4907                         echo 'install.libs \' >> Makefile
4908                         echo 'uninstall.libs ::' >> Makefile
4909                         echo '  ( cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@ )' >> Makefile
4910                         ;;
4911                 esac
4912         fi
4913
4914         if test -f "$srcdir/$cf_dir/modules" ; then
4915
4916                 if test "x$cf_cv_make_PHONY" = xyes ; then
4917                         cat >> Makefile <<-CF_EOF
4918
4919                         .PHONY :        install.$cf_dir
4920                         .PHONY :        uninstall.$cf_dir
4921 CF_EOF
4922                 fi
4923
4924                 echo >> Makefile
4925                 if test -f "$srcdir/$cf_dir/headers" ; then
4926 cat >> Makefile <<CF_EOF
4927 install.includes \\
4928 uninstall.includes \\
4929 CF_EOF
4930                 fi
4931
4932 cat >> Makefile <<CF_EOF
4933 lint \\
4934 libs \\
4935 lintlib \\
4936 install.libs \\
4937 uninstall.libs \\
4938 install.$cf_dir \\
4939 uninstall.$cf_dir ::
4940         ( cd "$cf_dir" && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4941 CF_EOF
4942         elif test -f "$srcdir/$cf_dir/headers" ; then
4943 cat >> Makefile <<CF_EOF
4944
4945 libs \\
4946 install.libs \\
4947 uninstall.libs \\
4948 install.includes \\
4949 uninstall.includes ::
4950         ( cd "$cf_dir" && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4951 CF_EOF
4952 fi
4953 done
4954
4955 if test "x$cf_cv_make_PHONY" = xyes ; then
4956         cat >> Makefile <<-CF_EOF
4957
4958         .PHONY :        install.data
4959         .PHONY :        uninstall.data
4960 CF_EOF
4961 fi
4962
4963 if test "x$cf_with_db_install" = xyes; then
4964 cat >> Makefile <<CF_EOF
4965
4966 install.libs uninstall.libs \\
4967 install.data uninstall.data ::
4968 $MAKE_TERMINFO  ( cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4969 CF_EOF
4970 else
4971 cat >> Makefile <<CF_EOF
4972
4973 install.libs uninstall.libs ::
4974         ( cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4975 CF_EOF
4976 fi
4977
4978 if test "x$cf_with_manpages" = xyes; then
4979
4980 if test "x$cf_cv_make_PHONY" = xyes ; then
4981         cat >> Makefile <<-CF_EOF
4982
4983         .PHONY :        install.man
4984         .PHONY :        uninstall.man
4985 CF_EOF
4986 fi
4987
4988 cat >> Makefile <<CF_EOF
4989
4990 install.man \\
4991 uninstall.man ::
4992         ( cd man && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4993 CF_EOF
4994 fi
4995
4996 cat >> Makefile <<CF_EOF
4997
4998 distclean ::
4999         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
5000         rm -f headers.sh headers.sed mk_shared_lib.sh
5001         rm -f edit_man.* man_alias.*
5002         rm -rf \${DIRS_TO_MAKE}
5003 CF_EOF
5004
5005 # Special case: tack's manpage lives in its own directory.
5006 if test "x$cf_with_manpages" = xyes; then
5007 if test "x$cf_with_tack" = "xyes"; then
5008 cat >> Makefile <<CF_EOF
5009
5010 install.man \\
5011 uninstall.man ::
5012         ( cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@ )
5013 CF_EOF
5014 fi
5015 fi
5016
5017 dnl If we're installing into a subdirectory of /usr/include, etc., we should
5018 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
5019 dnl anything, and will make it more standardized.  It's awkward to decide this
5020 dnl at configuration because of quoting, so we'll simply make all headers
5021 dnl installed via a script that can do the right thing.
5022
5023 rm -f headers.sed headers.sh
5024
5025 dnl ( generating this script makes the makefiles a little tidier :-)
5026 echo creating headers.sh
5027 cat >headers.sh <<CF_EOF
5028 #! $SHELL
5029 # This shell script is generated by the 'configure' script.  It is invoked in a
5030 # subdirectory of the build tree.  It generates a sed-script in the parent
5031 # directory that is used to adjust includes for header files that reside in a
5032 # subdirectory of /usr/include, etc.
5033 PRG=""
5034 while test \[$]# != 3
5035 do
5036 PRG="\$PRG \[$]1"; shift
5037 done
5038 DST=\[$]1
5039 REF=\[$]2
5040 SRC=\[$]3
5041 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
5042 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
5043 echo installing \$SRC in \$DST
5044 CF_EOF
5045
5046 if test "$WITH_CURSES_H" = yes; then
5047         cat >>headers.sh <<CF_EOF
5048 case \$DST in
5049 (/*/include/*)
5050         END=\`basename \$DST\`
5051         for i in \`cat \$REF/../*/headers |${FGREP-fgrep} -v "#"\`
5052         do
5053                 NAME=\`basename \$i\`
5054                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
5055         done
5056         ;;
5057 (*)
5058         echo "" >> \$TMPSED
5059         ;;
5060 esac
5061 CF_EOF
5062
5063 else
5064         cat >>headers.sh <<CF_EOF
5065 case \$DST in
5066 (/*/include/*)
5067         END=\`basename \$DST\`
5068         for i in \`cat \$REF/../*/headers |${FGREP-fgrep} -v "#"\`
5069         do
5070                 NAME=\`basename \$i\`
5071                 if test "\$NAME" = "curses.h"
5072                 then
5073                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
5074                         NAME=ncurses.h
5075                 fi
5076                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
5077         done
5078         ;;
5079 (*)
5080         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
5081         ;;
5082 esac
5083 CF_EOF
5084 fi
5085 cat >>headers.sh <<CF_EOF
5086 rm -f \$TMPSRC
5087 sed -f \$TMPSED \$SRC > \$TMPSRC
5088 NAME=\`basename \$SRC\`
5089 CF_EOF
5090 if test "$WITH_CURSES_H" != yes; then
5091         cat >>headers.sh <<CF_EOF
5092 test "\$NAME" = "curses.h" && NAME=ncurses.h
5093 CF_EOF
5094 fi
5095 cat >>headers.sh <<CF_EOF
5096 # Just in case someone gzip'd manpages, remove the conflicting copy.
5097 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
5098
5099 eval \$PRG \$TMPSRC \$DST/\$NAME
5100 rm -f \$TMPSRC \$TMPSED
5101 CF_EOF
5102
5103 chmod 0755 headers.sh
5104
5105 for cf_dir in $SRC_SUBDIRS
5106 do
5107         if test ! -d "$srcdir/$cf_dir" ; then
5108                 continue
5109         fi
5110
5111         if test -f "$srcdir/$cf_dir/headers" ; then
5112                 $AWK -f "$srcdir/mk-hdr.awk" \
5113                         subset="$LIB_SUBSETS" \
5114                         compat="$WITH_CURSES_H" \
5115                         "$srcdir/$cf_dir/headers" >>$cf_dir/Makefile
5116         fi
5117
5118         if test -f "$srcdir/$cf_dir/modules" ; then
5119                 if test "$cf_dir" != "c++" ; then
5120                         if test "x$cf_cv_make_PHONY" = xyes ; then
5121                                 cat >> $cf_dir/Makefile <<-CF_EOF
5122
5123                                 .PHONY :        depend
5124 CF_EOF
5125                         fi
5126
5127                         cat >>$cf_dir/Makefile <<"CF_EOF"
5128 depend : ${AUTO_SRC}
5129         makedepend -- ${CPPFLAGS} -- ${C_SRC}
5130
5131 # DO NOT DELETE THIS LINE -- make depend depends on it.
5132 CF_EOF
5133                 fi
5134         fi
5135 done
5136 AC_SUBST(Libs_To_Make)
5137 ])dnl
5138 dnl ---------------------------------------------------------------------------
5139 dnl CF_LIB_SONAME version: 9 updated: 2021/01/04 18:48:01
5140 dnl -------------
5141 dnl Find the and soname for the given shared library.  Set the cache variable
5142 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
5143 dnl variable to "unknown".
5144 dnl
5145 dnl $1 = headers
5146 dnl $2 = code
5147 dnl $3 = library name
5148 AC_DEFUN([CF_LIB_SONAME],
5149 [AC_REQUIRE([AC_PROG_FGREP])dnl
5150
5151 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
5152
5153 cf_cv_$3_soname=unknown
5154 if test "$cross_compiling" != yes ; then
5155 cat >conftest.$ac_ext <<CF_EOF
5156 $1
5157 int main(void)
5158 {
5159 $2
5160         ${cf_cv_main_return:-return}(0);
5161 }
5162 CF_EOF
5163 cf_save_LIBS="$LIBS"
5164         CF_ADD_LIB($3)
5165         if AC_TRY_EVAL(ac_compile) ; then
5166                 if AC_TRY_EVAL(ac_link) ; then
5167                         cf_cv_$3_soname="`ldd \"conftest$ac_exeext\" 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | ${FGREP-fgrep} lib$3.`"
5168                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
5169                 fi
5170         fi
5171 rm -rf ./conftest*
5172 LIBS="$cf_save_LIBS"
5173 fi
5174 ])
5175 ])
5176 dnl ---------------------------------------------------------------------------
5177 dnl CF_LIB_SUFFIX version: 28 updated: 2021/01/01 16:53:59
5178 dnl -------------
5179 dnl Compute the library file-suffix from the given model name
5180 dnl $1 = model name
5181 dnl $2 = variable to set (the nominal library suffix)
5182 dnl $3 = dependency variable to set (actual filename)
5183 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
5184 AC_DEFUN([CF_LIB_SUFFIX],
5185 [
5186         case X$1 in
5187         (Xlibtool)
5188                 $2='.la'
5189                 $3=[$]$2
5190                 ;;
5191         (Xdebug)
5192                 case "$cf_cv_system_name" in
5193                 (*-msvc*)
5194                         $2='_g.lib'
5195                         ;;
5196                 (*)
5197                         $2='_g.a'
5198                         ;;
5199                 esac
5200                 $3=[$]$2
5201                 ;;
5202         (Xprofile)
5203                 case "$cf_cv_system_name" in
5204                 (*-msvc*)
5205                         $2='_p.lib'
5206                         ;;
5207                 (*)
5208                         $2='_p.a'
5209                         ;;
5210                 esac
5211                 $3=[$]$2
5212                 ;;
5213         (Xshared)
5214                 case "$cf_cv_system_name" in
5215                 (aix[[5-7]]*)
5216                         $2='.so'
5217                         $3=[$]$2
5218                         ;;
5219                 (*-msvc*)
5220                         $2='.dll'
5221                         $3='.dll.lib'
5222                         ;;
5223                 (cygwin*|msys*|mingw*)
5224                         $2='.dll'
5225                         $3='.dll.a'
5226                         ;;
5227                 (darwin*)
5228                         $2='.dylib'
5229                         $3=[$]$2
5230                         ;;
5231                 (hpux*)
5232                         case "$target" in
5233                         (ia64*)
5234                                 $2='.so'
5235                                 $3=[$]$2
5236                                 ;;
5237                         (*)
5238                                 $2='.sl'
5239                                 $3=[$]$2
5240                                 ;;
5241                         esac
5242                         ;;
5243                 (*)
5244                         $2='.so'
5245                         $3=[$]$2
5246                         ;;
5247                 esac
5248                 ;;
5249         (*)
5250                 case "$target" in
5251                 (*-msvc*)
5252                         $2='.lib'
5253                         ;;
5254                 (*)
5255                         $2='.a'
5256                         ;;
5257                 esac
5258                 $3=[$]$2
5259                 ;;
5260         esac
5261         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
5262         then
5263                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
5264                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
5265         fi
5266 ])dnl
5267 dnl ---------------------------------------------------------------------------
5268 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
5269 dnl -----------
5270 dnl Compute the string to append to -library from the given model name
5271 dnl $1 = model name
5272 dnl $2 = variable to set
5273 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
5274 AC_DEFUN([CF_LIB_TYPE],
5275 [
5276         case $1 in
5277         (libtool) $2=''   ;;
5278         (normal)  $2=''   ;;
5279         (debug)   $2='_g' ;;
5280         (profile) $2='_p' ;;
5281         (shared)  $2=''   ;;
5282         esac
5283         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
5284 ])dnl
5285 dnl ---------------------------------------------------------------------------
5286 dnl CF_LINK_DATAONLY version: 13 updated: 2020/02/08 15:59:30
5287 dnl ----------------
5288 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
5289 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
5290 dnl have to provide wrappers for global tables to ensure they're linked
5291 dnl properly.
5292 AC_DEFUN([CF_LINK_DATAONLY],
5293 [
5294 AC_MSG_CHECKING([if data-only library module links])
5295 AC_CACHE_VAL(cf_cv_link_dataonly,[
5296         rm -f conftest.a
5297         cat >conftest.$ac_ext <<EOF
5298 #line __oline__ "configure"
5299 int     testdata[[3]] = { 123, 456, 789 };
5300 EOF
5301         if AC_TRY_EVAL(ac_compile) ; then
5302                 mv conftest.o data.o && \
5303                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
5304         fi
5305         rm -f conftest.$ac_ext data.o
5306         cat >conftest.$ac_ext <<EOF
5307 #line __oline__ "configure"
5308 int     testfunc(void)
5309 {
5310 #if defined(NeXT)
5311         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
5312 #else
5313         extern int testdata[[3]];
5314         return testdata[[0]] == 123
5315            &&  testdata[[1]] == 456
5316            &&  testdata[[2]] == 789;
5317 #endif
5318 }
5319 EOF
5320         if AC_TRY_EVAL(ac_compile); then
5321                 mv conftest.o func.o && \
5322                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
5323         fi
5324         rm -f conftest.$ac_ext func.o
5325         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
5326         cf_saveLIBS="$LIBS"
5327         LIBS="conftest.a $LIBS"
5328         AC_TRY_RUN([
5329         int main(void)
5330         {
5331                 extern int testfunc();
5332                 ${cf_cv_main_return:-return} (!testfunc());
5333         }
5334         ],
5335         [cf_cv_link_dataonly=yes],
5336         [cf_cv_link_dataonly=no],
5337         [cf_cv_link_dataonly=unknown])
5338         LIBS="$cf_saveLIBS"
5339         ])
5340 AC_MSG_RESULT($cf_cv_link_dataonly)
5341
5342 if test "$cf_cv_link_dataonly" = no ; then
5343         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
5344         BROKEN_LINKER=1
5345 fi
5346 AC_SUBST(BROKEN_LINKER)
5347
5348 ])dnl
5349 dnl ---------------------------------------------------------------------------
5350 dnl CF_LINK_FUNCS version: 11 updated: 2021/04/18 14:08:47
5351 dnl -------------
5352 dnl Most Unix systems have both link and symlink, a few don't have symlink.
5353 dnl A few non-Unix systems implement symlink, but not link.
5354 dnl A few non-systems implement neither (or have nonfunctional versions).
5355 dnl
5356 dnl This allows for a 2-second difference in modification times to allow for
5357 dnl some marginal NFS implementations.
5358 AC_DEFUN([CF_LINK_FUNCS],
5359 [
5360 AC_CHECK_HEADERS( \
5361 unistd.h \
5362 )
5363 AC_CHECK_FUNCS( \
5364         remove \
5365         unlink )
5366
5367 if test "$cross_compiling" = yes ; then
5368         AC_CHECK_FUNCS( \
5369                 link \
5370                 symlink )
5371 else
5372         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
5373                 cf_cv_link_funcs=
5374                 for cf_func in link symlink ; do
5375                         AC_TRY_RUN([
5376 #include <stdio.h>
5377 #include <sys/types.h>
5378 #include <sys/stat.h>
5379 #ifdef HAVE_UNISTD_H
5380 #include <unistd.h>
5381 #endif
5382 int main(void)
5383 {
5384         int fail = 0;
5385         char *src = "conftest.tmp";
5386         char *dst = "conftest.chk";
5387         struct stat src_sb, dst_sb;
5388         FILE *fp = fopen(src, "w");
5389         if (fp == 0) { fail = 3; } else {
5390                 fclose(fp); stat(src, &src_sb);
5391                 if ($cf_func(src, dst) < 0) {
5392                         fail = 1;
5393                 } else if (stat(dst, &dst_sb) < 0) {
5394                         fail = 2;
5395                 } else {
5396                         long diff = (dst_sb.st_mtime - src_sb.st_mtime);
5397                         if (diff < 0) diff = -diff;
5398                         if (diff > 2) fail = 3;
5399                 }
5400         }
5401 #ifdef HAVE_UNLINK
5402         unlink(dst); unlink(src);
5403 #else
5404         remove(dst); remove(src);
5405 #endif
5406         ${cf_cv_main_return:-return} (fail);
5407 }
5408                         ],[
5409                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
5410                         eval 'ac_cv_func_'$cf_func'=yes'],[
5411                         eval 'ac_cv_func_'$cf_func'=no'],[
5412                         eval 'ac_cv_func_'$cf_func'=error'])
5413                 done
5414                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
5415         ])
5416         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
5417         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
5418 fi
5419 ])dnl
5420 dnl ---------------------------------------------------------------------------
5421 dnl CF_MAKEFLAGS version: 21 updated: 2021/09/04 06:47:34
5422 dnl ------------
5423 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
5424 dnl options to lower-levels.  It is very useful for "make -n" -- if we have it.
5425 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
5426 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
5427 AC_DEFUN([CF_MAKEFLAGS],
5428 [AC_REQUIRE([AC_PROG_FGREP])dnl
5429
5430 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
5431         cf_cv_makeflags=''
5432         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
5433         do
5434                 cat >cf_makeflags.tmp <<CF_EOF
5435 SHELL = $SHELL
5436 all :
5437         @ echo '.$cf_option'
5438 CF_EOF
5439                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | ${FGREP-fgrep} -v "ing directory" | sed -e 's,[[  ]]*$,,'`
5440                 case "$cf_result" in
5441                 (.*k|.*kw)
5442                         cf_result="`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`"
5443                         case "$cf_result" in
5444                         (.*CC=*)        cf_cv_makeflags=
5445                                 ;;
5446                         (*)     cf_cv_makeflags=$cf_option
5447                                 ;;
5448                         esac
5449                         break
5450                         ;;
5451                 (.-)
5452                         ;;
5453                 (*)
5454                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
5455                         ;;
5456                 esac
5457         done
5458         rm -f cf_makeflags.tmp
5459 ])
5460
5461 AC_SUBST(cf_cv_makeflags)
5462 ])dnl
5463 dnl ---------------------------------------------------------------------------
5464 dnl CF_MAKE_PHONY version: 3 updated: 2021/01/08 16:08:21
5465 dnl -------------
5466 dnl Check if the make-program handles a ".PHONY" target, e.g,. a target which
5467 dnl acts as a placeholder.
5468 dnl
5469 dnl The ".PHONY" feature was proposed in 2011 here
5470 dnl     https://www.austingroupbugs.net/view.php?id=523
5471 dnl and is scheduled for release in P1003.1 Issue 8 (late 2022).
5472 dnl
5473 dnl This is not supported by SVr4 make (or SunOS 4, 4.3SD, etc), but works with
5474 dnl a few others (i.e., GNU make and the non-POSIX "BSD" make):
5475 dnl
5476 dnl + This is a GNU make feature (since April 1988, but in turn from binutils,
5477 dnl   date unspecified).
5478 dnl
5479 dnl + It was adopted in NetBSD make in June 1995.
5480 dnl
5481 dnl + The other BSD make programs are derived from the NetBSD make (and for
5482 dnl   that reason are not actually different "implementations").
5483 dnl
5484 dnl + Some features of NetBSD make were actually adapted from pmake, which
5485 dnl   began as a modified GNU make starting in 1993.
5486 dnl
5487 dnl + Version 3.8 of the dmake program in January 1992 also implemented this
5488 dnl   GNU make extension, but is less well known than the BSD make.
5489 AC_DEFUN([CF_MAKE_PHONY],[
5490 AC_CACHE_CHECK(for \".PHONY\" make-support, cf_cv_make_PHONY,[
5491         rm -rf conftest*
5492         (
5493                 mkdir conftest || exit 1
5494                 cd conftest
5495                 cat >makefile <<'CF_EOF'
5496 .PHONY: always
5497 DATA=0
5498 always: always.out
5499         @echo "** making [$]@ [$](DATA)"
5500 once: once.out
5501         @echo "** making [$]@ [$](DATA)"
5502 always.out:
5503         @echo "** making [$]@ [$](DATA)"
5504         echo [$](DATA) > [$]@
5505 once.out:
5506         @echo "** making [$]@ [$](DATA)"
5507         echo [$](DATA) > [$]@
5508 CF_EOF
5509                 for cf_data in 1 2 3
5510                 do
5511                         ${MAKE:-make} always DATA=$cf_data
5512                         ${MAKE:-make} once   DATA=$cf_data
5513                         ${MAKE:-make} -t always once
5514                         if test -f always ; then
5515                                 echo "no (case 1)" > ../conftest.tmp
5516                         elif test ! -f always.out ; then
5517                                 echo "no (case 2)" > ../conftest.tmp
5518                         elif test ! -f once.out ; then
5519                                 echo "no (case 3)" > ../conftest.tmp
5520                         elif ! cmp -s always.out once.out ; then
5521                                 echo "no (case 4)" > ../conftest.tmp
5522                                 diff always.out once.out
5523                         else
5524                                 cf_check="`cat always.out`"
5525                                 if test "x$cf_check" != "x$cf_data" ; then
5526                                         echo "no (case 5)" > ../conftest.tmp
5527                                 else
5528                                         echo yes > ../conftest.tmp
5529                                         rm -f ./*.out
5530                                         continue
5531                                 fi
5532                         fi
5533                         break
5534                 done
5535         ) >&AC_FD_CC 2>&1
5536         cf_cv_make_PHONY="`cat conftest.tmp`"
5537         rm -rf conftest*
5538 ])
5539 MAKE_NO_PHONY="#"
5540 MAKE_PHONY="#"
5541 test "x$cf_cv_make_PHONY" = xyes && MAKE_PHONY=
5542 test "x$cf_cv_make_PHONY" != xyes && MAKE_NO_PHONY=
5543 AC_SUBST(MAKE_NO_PHONY)
5544 AC_SUBST(MAKE_PHONY)
5545 ])dnl
5546 dnl ---------------------------------------------------------------------------
5547 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
5548 dnl ------------
5549 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
5550 dnl a monocase filesystem.
5551 AC_DEFUN([CF_MAKE_TAGS],[
5552 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
5553
5554 AC_CHECK_PROGS(CTAGS, exctags ctags)
5555 AC_CHECK_PROGS(ETAGS, exetags etags)
5556
5557 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
5558
5559 if test "$cf_cv_mixedcase" = yes ; then
5560         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
5561 else
5562         MAKE_UPPER_TAGS=no
5563 fi
5564
5565 if test "$MAKE_UPPER_TAGS" = yes ; then
5566         MAKE_UPPER_TAGS=
5567 else
5568         MAKE_UPPER_TAGS="#"
5569 fi
5570
5571 if test "$MAKE_LOWER_TAGS" = yes ; then
5572         MAKE_LOWER_TAGS=
5573 else
5574         MAKE_LOWER_TAGS="#"
5575 fi
5576
5577 AC_SUBST(CTAGS)
5578 AC_SUBST(ETAGS)
5579
5580 AC_SUBST(MAKE_UPPER_TAGS)
5581 AC_SUBST(MAKE_LOWER_TAGS)
5582 ])dnl
5583 dnl ---------------------------------------------------------------------------
5584 dnl CF_MANPAGE_FORMAT version: 16 updated: 2022/11/05 16:12:11
5585 dnl -----------------
5586 dnl Option to allow user to override automatic configuration of manpage format.
5587 dnl There are several special cases:
5588 dnl
5589 dnl     compress - man checks for, can display compressed files
5590 dnl     bzip2 - man checks for, can display bzip2'd files
5591 dnl     gzip - man checks for, can display gzip'd files
5592 dnl     xz - man checks for, can display xz'd files
5593 dnl
5594 dnl     BSDI - files in the cat-directories are suffixed ".0"
5595 dnl     formatted - installer should format (put files in cat-directory)
5596 dnl     catonly - installer should only format, e.g., for a turnkey system.
5597 dnl
5598 dnl There are other configurations which this macro does not test, e.g., HPUX's
5599 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
5600 dnl convention would not match our use).
5601 AC_DEFUN([CF_MANPAGE_FORMAT],
5602 [
5603 AC_REQUIRE([CF_PATHSEP])
5604 AC_MSG_CHECKING(format of man-pages)
5605
5606 AC_ARG_WITH(manpage-format,
5607         [  --with-manpage-format   specify manpage-format: gzip/compress/bzip2/xz,
5608                           BSDI/normal and optionally formatted/catonly,
5609                           e.g., gzip,formatted],
5610         [MANPAGE_FORMAT=$withval],
5611         [MANPAGE_FORMAT=unknown])
5612
5613 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
5614 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
5615
5616 cf_unknown=
5617
5618 case "$MANPAGE_FORMAT" in
5619 (unknown)
5620         if test -z "$MANPATH" ; then
5621                 MANPATH="/usr/man:/usr/share/man"
5622         fi
5623
5624         # look for the 'date' man-page (it is most likely to be installed!)
5625         MANPAGE_FORMAT=
5626         cf_preform="no"
5627         cf_catonly="yes"
5628         cf_example="date"
5629
5630         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
5631         for cf_dir in $MANPATH; do
5632                 test -z "$cf_dir" && cf_dir=/usr/man
5633                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
5634                 do
5635                         cf_test=`echo "$cf_name" | sed -e 's/*//'`
5636                         if test "x$cf_test" = "x$cf_name" ; then
5637
5638                                 case "$cf_name" in
5639                                 (*.bz2) MANPAGE_FORMAT="$MANPAGE_FORMAT bzip2";;
5640                                 (*.xz)  MANPAGE_FORMAT="$MANPAGE_FORMAT xz";;
5641                                 (*.gz)  MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
5642                                 (*.Z)   MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
5643                                 (*.0)   MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
5644                                 (*)     MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
5645                                 esac
5646
5647                                 case "$cf_name" in
5648                                 ($cf_dir/man*)
5649                                         cf_catonly=no
5650                                         ;;
5651                                 ($cf_dir/cat*)
5652                                         cf_preform=yes
5653                                         ;;
5654                                 esac
5655                                 break
5656                         fi
5657
5658                         # if we found a match in either man* or cat*, stop looking
5659                         if test -n "$MANPAGE_FORMAT" ; then
5660                                 cf_found=no
5661                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
5662                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
5663                                 case "$cf_name" in
5664                                 ($cf_dir/cat*)
5665                                         cf_found=yes
5666                                         ;;
5667                                 esac
5668                                 test "$cf_found" = yes && break
5669                         fi
5670                 done
5671                 # only check the first directory in $MANPATH where we find manpages
5672                 if test -n "$MANPAGE_FORMAT" ; then
5673                         break
5674                 fi
5675         done
5676         # if we did not find the example, just assume it is normal
5677         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
5678         IFS="$ac_save_ifs"
5679         ;;
5680 (*)
5681         for cf_option in $MANPAGE_FORMAT; do
5682         case "$cf_option" in
5683         (xz|bzip2|gzip|compress|BSDI|normal|formatted|catonly)
5684                 ;;
5685         (*)
5686                 cf_unknown="$cf_unknown $cf_option"
5687                 ;;
5688         esac
5689         done
5690         ;;
5691 esac
5692
5693 AC_MSG_RESULT($MANPAGE_FORMAT)
5694 if test -n "$cf_unknown" ; then
5695         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
5696 fi
5697 ])dnl
5698 dnl ---------------------------------------------------------------------------
5699 dnl CF_MANPAGE_RENAMES version: 17 updated: 2022/10/23 07:46:29
5700 dnl ------------------
5701 dnl The Debian people have their own naming convention for manpages.  This
5702 dnl option lets us override the name of the file containing renaming, or
5703 dnl disable it altogether.
5704 AC_DEFUN([CF_MANPAGE_RENAMES],
5705 [
5706 AC_MSG_CHECKING(for manpage renaming)
5707
5708 AC_ARG_WITH(manpage-renames,
5709         [  --with-manpage-renames  specify manpage-renaming],
5710         [MANPAGE_RENAMES=$withval],
5711         [MANPAGE_RENAMES=yes])
5712
5713 case ".$MANPAGE_RENAMES" in
5714 (.no)
5715         ;;
5716 (.|.yes)
5717         # Debian 'man' program?
5718         if test -f /etc/debian_version ; then
5719                 MANPAGE_RENAMES=man/man_db.renames
5720         else
5721                 MANPAGE_RENAMES=no
5722         fi
5723         ;;
5724 esac
5725
5726 if test "$MANPAGE_RENAMES" = man/man_db.renames ; then
5727         MANPAGE_RENAMES=`pwd`/$MANPAGE_RENAMES
5728 elif test "$MANPAGE_RENAMES" = no ; then
5729         :
5730 elif test ! -f "$MANPAGE_RENAMES" ; then
5731         AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
5732 fi
5733
5734 AC_MSG_RESULT($MANPAGE_RENAMES)
5735 AC_SUBST(MANPAGE_RENAMES)
5736 ])dnl
5737 dnl ---------------------------------------------------------------------------
5738 dnl CF_MANPAGE_SYMLINKS version: 6 updated: 2015/04/17 21:13:04
5739 dnl -------------------
5740 dnl Some people expect each tool to make all aliases for manpages in the
5741 dnl man-directory.  This accommodates the older, less-capable implementations
5742 dnl of 'man', and is optional.
5743 AC_DEFUN([CF_MANPAGE_SYMLINKS],
5744 [
5745 AC_MSG_CHECKING(if manpage aliases will be installed)
5746
5747 AC_ARG_WITH(manpage-aliases,
5748         [  --with-manpage-aliases  specify manpage-aliases using .so],
5749         [MANPAGE_ALIASES=$withval],
5750         [MANPAGE_ALIASES=yes])
5751
5752 AC_MSG_RESULT($MANPAGE_ALIASES)
5753
5754 case "x$LN_S" in
5755 (xln*)
5756         cf_use_symlinks=yes
5757         ;;
5758 (*)
5759         cf_use_symlinks=no
5760         ;;
5761 esac
5762
5763 MANPAGE_SYMLINKS=no
5764 if test "$MANPAGE_ALIASES" = yes ; then
5765 AC_MSG_CHECKING(if manpage symlinks should be used)
5766
5767 AC_ARG_WITH(manpage-symlinks,
5768         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
5769         [MANPAGE_SYMLINKS=$withval],
5770         [MANPAGE_SYMLINKS=$cf_use_symlinks])
5771
5772 if test "$$cf_use_symlinks" = no; then
5773 if test "$MANPAGE_SYMLINKS" = yes ; then
5774         AC_MSG_WARN(cannot make symlinks, will use .so files)
5775         MANPAGE_SYMLINKS=no
5776 fi
5777 fi
5778
5779 AC_MSG_RESULT($MANPAGE_SYMLINKS)
5780 fi
5781
5782 ])dnl
5783 dnl ---------------------------------------------------------------------------
5784 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
5785 dnl --------------
5786 dnl This option causes manpages to be run through tbl(1) to generate tables
5787 dnl correctly.
5788 AC_DEFUN([CF_MANPAGE_TBL],
5789 [
5790 AC_MSG_CHECKING(for manpage tbl)
5791
5792 AC_ARG_WITH(manpage-tbl,
5793         [  --with-manpage-tbl      specify manpage processing with tbl],
5794         [MANPAGE_TBL=$withval],
5795         [MANPAGE_TBL=no])
5796
5797 AC_MSG_RESULT($MANPAGE_TBL)
5798 ])dnl
5799 dnl ---------------------------------------------------------------------------
5800 dnl CF_MAN_PAGES version: 54 updated: 2022/11/05 16:12:11
5801 dnl ------------
5802 dnl Try to determine if the man-pages on the system are compressed, and if
5803 dnl so, what format is used.  Use this information to construct a script that
5804 dnl will install man-pages.
5805 AC_DEFUN([CF_MAN_PAGES],
5806 [
5807 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
5808 CF_MANPAGE_FORMAT
5809 CF_MANPAGE_RENAMES
5810 CF_MANPAGE_SYMLINKS
5811 CF_MANPAGE_TBL
5812
5813 if test "$prefix" = "NONE" ; then
5814         cf_prefix="$ac_default_prefix"
5815 else
5816         cf_prefix="$prefix"
5817 fi
5818
5819 case "$MANPAGE_FORMAT" in
5820 (*catonly*)
5821         cf_format=yes
5822         cf_inboth=no
5823         ;;
5824 (*formatted*)
5825         cf_format=yes
5826         cf_inboth=yes
5827         ;;
5828 (*)
5829         cf_format=no
5830         cf_inboth=no
5831         ;;
5832 esac
5833
5834 test ! -d man && mkdir man
5835
5836 cf_so_strip=
5837 cf_compress=
5838 for cf_manpage_format in $MANPAGE_FORMAT
5839 do
5840 case "$cf_manpage_format" in
5841 (compress)
5842         cf_so_strip="Z"
5843         cf_compress=compress
5844         ;;
5845 (gzip)
5846         cf_so_strip="gz"
5847         cf_compress=gzip
5848         ;;
5849 (bzip2)
5850         cf_so_strip="bz2"
5851         cf_compress=bzip2
5852         ;;
5853 (xz)
5854         cf_so_strip="xz"
5855         cf_compress=xz
5856         ;;
5857 esac
5858 done
5859
5860 cf_edit_man=./edit_man.sh
5861 cf_man_alias=`pwd`/man_alias.sed
5862
5863 cat >$cf_edit_man <<CF_EOF
5864 #! $SHELL
5865 # this script is generated by the configure-script CF_MAN_PAGES macro.
5866
5867 prefix="$cf_prefix"
5868 datarootdir="$datarootdir"
5869 datadir="$datadir"
5870
5871 NCURSES_MAJOR="$NCURSES_MAJOR"
5872 NCURSES_MINOR="$NCURSES_MINOR"
5873 NCURSES_PATCH="$NCURSES_PATCH"
5874
5875 NCURSES_OSPEED="$NCURSES_OSPEED"
5876 TERMINFO="$TERMINFO"
5877
5878 INSTALL="$INSTALL"
5879 INSTALL_DATA="$INSTALL_DATA"
5880
5881 transform="$program_transform_name"
5882
5883 TMP=\${TMPDIR:=/tmp}/man\$\$
5884 trap "rm -f \$TMP; exit 1" 1 2 3 15
5885 trap "rm -f \$TMP" 0
5886
5887 form=\[$]1
5888 shift || exit 1
5889
5890 verb=\[$]1
5891 shift || exit 1
5892
5893 mandir=\[$]1
5894 shift || exit 1
5895
5896 srcdir=\[$]1
5897 top_srcdir=\[$]srcdir/..
5898 shift || exit 1
5899
5900 if test "\$form" = normal ; then
5901         if test "$cf_format" = yes ; then
5902         if test "$cf_inboth" = no ; then
5903                 $SHELL "\[$]0" format "\$verb" "\$mandir" "\$srcdir" "\[$]@"
5904                 exit $?
5905         fi
5906         fi
5907         cf_subdir=\$mandir/man
5908         cf_tables=$MANPAGE_TBL
5909 else
5910         cf_subdir=\$mandir/cat
5911         cf_tables=yes
5912 fi
5913
5914 # process the list of source-files
5915 for i in "\[$]@" ; do
5916 case \$i in
5917 (*.orig|*.rej) ;;
5918 (*.[[0-9]]*)
5919         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
5920         if test "\$verb" = installing ; then
5921         if test ! -d "\$cf_subdir\${section}" ; then
5922                 mkdir -p "\$cf_subdir\$section"
5923         fi
5924         fi
5925
5926         # replace variables in man page
5927         if test ! -f "$cf_man_alias" ; then
5928 cat >>$cf_man_alias <<-CF_EOF2
5929                 s,@DATADIR@,\$datadir,g
5930                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
5931                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
5932                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
5933                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
5934                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
5935                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
5936 CF_EOF
5937         ifelse($1,,,[
5938         for cf_name in $1
5939         do
5940                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
5941                 cf_name=`echo "$cf_name" | sed "$program_transform_name"`
5942 cat >>$cf_edit_man <<-CF_EOF
5943                 s,@$cf_NAME@,$cf_name,g
5944 CF_EOF
5945         done
5946         ])
5947 cat >>$cf_edit_man <<CF_EOF
5948 CF_EOF2
5949                 echo "...made $cf_man_alias"
5950         fi
5951
5952         aliases=
5953         cf_source=\`basename "\$i"\`
5954         inalias=\$cf_source
5955         test ! -f "\$inalias" && inalias="\$srcdir/\$inalias"
5956         if test ! -f "\$inalias" ; then
5957                 echo ".. skipped \$cf_source"
5958                 continue
5959         fi
5960 CF_EOF
5961
5962 if test "$MANPAGE_ALIASES" != no ; then
5963 cat >>$cf_edit_man <<CF_EOF
5964         nCurses=ignore.3x
5965         test "$with_curses_h" = yes && nCurses=ncurses.3x
5966         aliases=\`sed -f "\$top_srcdir/man/manlinks.sed" "\$inalias" |sed -f "$cf_man_alias" | sort -u; test "\$inalias" = "\$nCurses" && echo curses\`
5967 CF_EOF
5968 fi
5969
5970 if test "$MANPAGE_RENAMES" = no ; then
5971 cat >>$cf_edit_man <<CF_EOF
5972         # perform program transformations for section 1 man pages
5973         if test \$section = 1 ; then
5974                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
5975         else
5976                 cf_target=\$cf_subdir\${section}/\$cf_source
5977         fi
5978 CF_EOF
5979 else
5980 cat >>$cf_edit_man <<CF_EOF
5981         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
5982         if test -z "\$cf_target" ; then
5983                 echo "? missing rename for \$cf_source"
5984                 cf_target="\$cf_source"
5985         fi
5986         cf_target="\$cf_subdir\${section}/\${cf_target}"
5987
5988 CF_EOF
5989 fi
5990
5991 cat >>$cf_edit_man <<CF_EOF
5992         sed     -f "$cf_man_alias" \\
5993 CF_EOF
5994
5995 if test "$MANPAGE_RENAMES" != no ; then
5996 cat >>$cf_edit_man <<CF_EOF
5997                 < "\$i" | sed -f `pwd`/edit_man.sed >\$TMP
5998 CF_EOF
5999 else
6000 cat >>$cf_edit_man <<CF_EOF
6001                 < "\$i" >\$TMP
6002 CF_EOF
6003 fi
6004
6005 cat >>$cf_edit_man <<CF_EOF
6006 if test \$cf_tables = yes ; then
6007         tbl \$TMP >\$TMP.out
6008         mv \$TMP.out \$TMP
6009 fi
6010 CF_EOF
6011
6012 if test "$with_overwrite" != yes ; then
6013 cat >>$cf_edit_man <<CF_EOF
6014         sed -e "/\\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
6015         mv \$TMP.out \$TMP
6016 CF_EOF
6017 fi
6018
6019 if test "$with_curses_h" != yes ; then
6020 cat >>$cf_edit_man <<CF_EOF
6021         sed -e "/\\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
6022         mv \$TMP.out \$TMP
6023 CF_EOF
6024 fi
6025
6026 cat >>$cf_edit_man <<CF_EOF
6027         if test "\$form" = format ; then
6028                 nroff -man \$TMP >\$TMP.out
6029                 mv \$TMP.out \$TMP
6030         fi
6031 CF_EOF
6032
6033 if test -n "$cf_compress" ; then
6034 cat >>$cf_edit_man <<CF_EOF
6035         if test "\$verb" = installing ; then
6036         if ( "$cf_compress" -f \$TMP )
6037         then
6038                 mv \$TMP.$cf_so_strip \$TMP
6039         fi
6040         fi
6041         cf_target="\$cf_target.$cf_so_strip"
6042 CF_EOF
6043 fi
6044
6045 case "$MANPAGE_FORMAT" in
6046 (*BSDI*)
6047 cat >>$cf_edit_man <<CF_EOF
6048         if test "\$form" = format ; then
6049                 # BSDI installs only .0 suffixes in the cat directories
6050                 cf_target="\`echo \$cf_target|sed -e 's/\\.[[1-9]]\\+[[a-z]]*/.0/'\`"
6051         fi
6052 CF_EOF
6053   ;;
6054 esac
6055
6056 cat >>$cf_edit_man <<CF_EOF
6057         suffix=\`basename "\$cf_target" | sed -e 's%^[[^.]]*%%'\`
6058         if test "\$verb" = installing ; then
6059                 echo "\$verb \$cf_target"
6060                 \$INSTALL_DATA \$TMP "\$cf_target"
6061                 test -d "\$cf_subdir\${section}" &&
6062                 test -n "\$aliases" && (
6063                         cd "\$cf_subdir\${section}" && (
6064                                 cf_source=\`echo "\$cf_target" |sed -e 's%^.*/\\([[^/]][[^/]]*/[[^/]][[^/]]*$\\)%\\1%'\`
6065                                 test -n "$cf_so_strip" && cf_source=\`echo "\$cf_source" |sed -e 's%\\.$cf_so_strip\$%%'\`
6066                                 cf_target=\`basename "\$cf_target"\`
6067                                 for cf_alias in \$aliases
6068                                 do
6069                                         if test "\$section" = 1 ; then
6070                                                 cf_alias=\`echo "\$cf_alias" |sed "\${transform}"\`
6071                                         fi
6072
6073                                         if test "$MANPAGE_SYMLINKS" = yes ; then
6074                                                 if test -f "\$cf_alias\${suffix}" ; then
6075                                                         if ( cmp -s "\$cf_target" "\$cf_alias\${suffix}" )
6076                                                         then
6077                                                                 continue
6078                                                         fi
6079                                                 fi
6080                                                 echo ".. \$verb alias \$cf_alias\${suffix}"
6081 CF_EOF
6082 case "x$LN_S" in
6083 (*-f)
6084 cat >>$cf_edit_man <<CF_EOF
6085                                                 $LN_S "\$cf_target" "\$cf_alias\${suffix}"
6086 CF_EOF
6087         ;;
6088 (*)
6089 cat >>$cf_edit_man <<CF_EOF
6090                                                 rm -f "\$cf_alias\${suffix}"
6091                                                 $LN_S "\$cf_target" "\$cf_alias\${suffix}"
6092 CF_EOF
6093         ;;
6094 esac
6095 cat >>$cf_edit_man <<CF_EOF
6096                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
6097                                                 echo ".so \$cf_source" >\$TMP
6098 CF_EOF
6099 if test -n "$cf_compress" ; then
6100 cat >>$cf_edit_man <<CF_EOF
6101                                                 if test -n "$cf_so_strip" ; then
6102                                                         "$cf_compress" -f \$TMP
6103                                                         mv \$TMP.$cf_so_strip \$TMP
6104                                                 fi
6105 CF_EOF
6106 fi
6107 cat >>$cf_edit_man <<CF_EOF
6108                                                 echo ".. \$verb alias \$cf_alias\${suffix}"
6109                                                 rm -f "\$cf_alias\${suffix}"
6110                                                 \$INSTALL_DATA \$TMP "\$cf_alias\${suffix}"
6111                                         fi
6112                                 done
6113                         )
6114                 )
6115         elif test "\$verb" = removing ; then
6116                 test -f "\$cf_target" && (
6117                         echo "\$verb \$cf_target"
6118                         rm -f "\$cf_target"
6119                 )
6120                 test -d "\$cf_subdir\${section}" &&
6121                 test -n "\$aliases" && (
6122                         cd "\$cf_subdir\${section}" && (
6123                                 for cf_alias in \$aliases
6124                                 do
6125                                         if test "\$section" = 1 ; then
6126                                                 cf_alias=\`echo "\$cf_alias" |sed "\${transform}"\`
6127                                         fi
6128
6129                                         echo ".. \$verb alias \$cf_alias\${suffix}"
6130                                         rm -f "\$cf_alias\${suffix}"
6131                                 done
6132                         )
6133                 )
6134         else
6135 #               echo ".hy 0"
6136                 cat \$TMP
6137         fi
6138         ;;
6139 esac
6140 done
6141
6142 if test "$cf_inboth" = yes ; then
6143 if test "\$form" != format ; then
6144         $SHELL "\[$]0" format "\$verb" "\$mandir" "\$srcdir" "\[$]@"
6145 fi
6146 fi
6147
6148 exit 0
6149 CF_EOF
6150 chmod 755 "$cf_edit_man"
6151
6152 ])dnl
6153 dnl ---------------------------------------------------------------------------
6154 dnl CF_MAP_LIB_BASENAME version: 2 updated: 2021/01/02 17:09:14
6155 dnl -------------------
6156 dnl Convert a default-libname to the actual one used via CF_WITH_LIB_BASENAME.
6157 dnl
6158 dnl $1 = variable to set
6159 dnl $2 = default-libname
6160 AC_DEFUN([CF_MAP_LIB_BASENAME],[
6161 CF_UPPER(cf_map_lib_basename,$2)
6162 eval $1="\$${cf_map_lib_basename}_NAME"
6163 ])dnl
6164 dnl ---------------------------------------------------------------------------
6165 dnl CF_MATH_LIB version: 11 updated: 2022/07/27 19:01:48
6166 dnl -----------
6167 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
6168 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
6169 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
6170 AC_DEFUN([CF_MATH_LIB],
6171 [
6172 AC_CACHE_CHECK(if -lm needed for math functions,
6173         cf_cv_need_libm,[
6174         AC_TRY_LINK([
6175                 #include <stdio.h>
6176                 #include <stdlib.h>
6177                 #include <math.h>
6178         ],
6179         [double x = rand(); printf("result = %g\\n", ]ifelse([$2],,sin(x),$2)[)],
6180         [cf_cv_need_libm=no],
6181         [cf_cv_need_libm=yes])])
6182
6183 if test "$cf_cv_need_libm" = yes
6184 then
6185
6186         cf_save_LIBS="$LIBS"
6187         LIBS="$LIBS -lm"
6188         AC_CACHE_CHECK(if -lm is available for math functions,
6189         cf_cv_have_libm,[
6190         AC_TRY_LINK([
6191                 #include <stdio.h>
6192                 #include <stdlib.h>
6193                 #include <math.h>
6194         ],
6195         [double x = rand(); printf("result = %g\\n", ]ifelse([$2],,sin(x),$2)[)],
6196         [cf_cv_have_libm=yes],
6197         [cf_cv_have_libm=no])])
6198         LIBS="$cf_save_LIBS"
6199
6200         if test "$cf_cv_have_libm" = yes
6201         then
6202                 ifelse($1,,[CF_ADD_LIB(m)],[$1=-lm])
6203         fi
6204 else
6205         cf_cv_have_libm=yes
6206 fi
6207
6208 if test "$cf_cv_have_libm" = yes
6209 then
6210         AC_DEFINE(HAVE_MATH_FUNCS,1,[Define to 1 if math functions are available])
6211 fi
6212 ])
6213 dnl ---------------------------------------------------------------------------
6214 dnl CF_MIXEDCASE_FILENAMES version: 9 updated: 2021/01/01 16:53:59
6215 dnl ----------------------
6216 dnl Check if the file-system supports mixed-case filenames.  If we're able to
6217 dnl create a lowercase name and see it as uppercase, it doesn't support that.
6218 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
6219 [
6220 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
6221 if test "$cross_compiling" = yes ; then
6222         case "$target_alias" in
6223         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*|darwin*)
6224                 cf_cv_mixedcase=no
6225                 ;;
6226         (*)
6227                 cf_cv_mixedcase=yes
6228                 ;;
6229         esac
6230 else
6231         rm -f conftest CONFTEST
6232         echo test >conftest
6233         if test -f CONFTEST ; then
6234                 cf_cv_mixedcase=no
6235         else
6236                 cf_cv_mixedcase=yes
6237         fi
6238         rm -f conftest CONFTEST
6239 fi
6240 ])
6241 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
6242 ])dnl
6243 dnl ---------------------------------------------------------------------------
6244 dnl CF_MKSTEMP version: 11 updated: 2021/01/01 13:31:04
6245 dnl ----------
6246 dnl Check for a working mkstemp.  This creates two files, checks that they are
6247 dnl successfully created and distinct (AmigaOS apparently fails on the last).
6248 AC_DEFUN([CF_MKSTEMP],[
6249 AC_CHECK_HEADERS( \
6250 unistd.h \
6251 )
6252 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
6253 rm -rf ./conftest*
6254 AC_TRY_RUN([
6255 #include <sys/types.h>
6256 #ifdef HAVE_UNISTD_H
6257 #include <unistd.h>
6258 #endif
6259 #include <stdlib.h>
6260 #include <stdio.h>
6261 #include <string.h>
6262 #include <sys/stat.h>
6263 int main(void)
6264 {
6265         char *tmpl = "conftestXXXXXX";
6266         char name[2][80];
6267         int n;
6268         int result = 0;
6269         int fd;
6270         struct stat sb;
6271
6272         umask(077);
6273         for (n = 0; n < 2; ++n) {
6274                 strcpy(name[n], tmpl);
6275                 if ((fd = mkstemp(name[n])) >= 0) {
6276                         if (!strcmp(name[n], tmpl)
6277                          || stat(name[n], &sb) != 0
6278                          || (sb.st_mode & S_IFMT) != S_IFREG
6279                          || (sb.st_mode & 077) != 0) {
6280                                 result = 1;
6281                         }
6282                         close(fd);
6283                 }
6284         }
6285         if (result == 0
6286          && !strcmp(name[0], name[1]))
6287                 result = 1;
6288         ${cf_cv_main_return:-return}(result);
6289 }
6290 ],[cf_cv_func_mkstemp=yes
6291 ],[cf_cv_func_mkstemp=no
6292 ],[cf_cv_func_mkstemp=maybe])
6293 ])
6294 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
6295         AC_CHECK_FUNC(mkstemp)
6296 fi
6297 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
6298         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
6299 fi
6300 ])dnl
6301 dnl ---------------------------------------------------------------------------
6302 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
6303 dnl ----------
6304 dnl Write a debug message to config.log, along with the line number in the
6305 dnl configure script.
6306 AC_DEFUN([CF_MSG_LOG],[
6307 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
6308 ])dnl
6309 dnl ---------------------------------------------------------------------------
6310 dnl CF_NCURSES_ABI_6 version: 4 updated: 2021/01/01 13:31:04
6311 dnl ----------------
6312 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
6313 dnl warn about this.
6314 AC_DEFUN([CF_NCURSES_ABI_6],[
6315 if test "${with_abi_version+set}" != set; then
6316         case "$cf_cv_rel_version" in
6317         (5.*)
6318                 cf_cv_rel_version=6.0
6319                 cf_cv_abi_version=6
6320                 AC_MSG_WARN(overriding ABI version to $cf_cv_abi_version)
6321                 ;;
6322         esac
6323 fi
6324 ])dnl
6325 dnl ---------------------------------------------------------------------------
6326 dnl CF_NCURSES_WITH_ABI_VERSION version: 3 updated: 2021/01/01 13:31:04
6327 dnl ---------------------------
6328 dnl Allow ncurses's ABI to be overridden.  Generally this happens when a
6329 dnl packager has incremented the ABI past that used in the original package,
6330 dnl and wishes to keep doing this.
6331 dnl
6332 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
6333 dnl symbol.
6334 AC_DEFUN([CF_NCURSES_WITH_ABI_VERSION],[
6335 CF_WITH_ABI_VERSION($1)
6336 if test "x$cf_cv_abi_version" != "x$with_abi_version"
6337 then
6338         case "$cf_cv_rel_version" in
6339         (5.*)
6340                 cf_cv_rel_version=$with_abi_version.0
6341                 ;;
6342         esac
6343 fi
6344 ])dnl
6345 dnl ---------------------------------------------------------------------------
6346 dnl CF_NO_LEAKS_OPTION version: 9 updated: 2021/06/13 19:45:41
6347 dnl ------------------
6348 dnl see CF_WITH_NO_LEAKS
6349 dnl
6350 dnl $1 = option/name
6351 dnl $2 = help-text
6352 dnl $3 = symbol to define if the option is set
6353 dnl $4 = additional actions to take if the option is set
6354 AC_DEFUN([CF_NO_LEAKS_OPTION],[
6355 AC_MSG_CHECKING(if you want to use $1 for testing)
6356 AC_ARG_WITH($1,
6357         [$2],
6358         [case "x$withval" in
6359         (x|xno) ;;
6360         (*)
6361                 : "${with_cflags:=-g}"
6362                 : "${enable_leaks:=no}"
6363                 with_$1=yes
6364                 AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
6365          $4
6366 ])
6367                 ;;
6368         esac],
6369         [with_$1=])
6370 AC_MSG_RESULT(${with_$1:-no})
6371
6372 case ".$with_cflags" in
6373 (.*-g*)
6374         case .$CFLAGS in
6375         (.*-g*)
6376                 ;;
6377         (*)
6378                 CF_ADD_CFLAGS([-g])
6379                 ;;
6380         esac
6381         ;;
6382 esac
6383 ])dnl
6384 dnl ---------------------------------------------------------------------------
6385 dnl CF_NUMBER_SYNTAX version: 2 updated: 2015/04/17 21:13:04
6386 dnl ----------------
6387 dnl Check if the given variable is a number.  If not, report an error.
6388 dnl $1 is the variable
6389 dnl $2 is the message
6390 AC_DEFUN([CF_NUMBER_SYNTAX],[
6391 if test -n "$1" ; then
6392   case $1 in
6393   ([[0-9]]*)
6394         ;;
6395   (*)
6396         AC_MSG_ERROR($2 is not a number: $1)
6397         ;;
6398   esac
6399 else
6400   AC_MSG_ERROR($2 value is empty)
6401 fi
6402 ])dnl
6403 dnl ---------------------------------------------------------------------------
6404 dnl CF_OBJ_SUBDIR version: 8 updated: 2021/01/01 13:31:04
6405 dnl -------------
6406 dnl Compute the object-directory name from the given model name
6407 AC_DEFUN([CF_OBJ_SUBDIR],
6408 [
6409         case $1 in
6410         (libtool) $2='obj_lo'  ;;
6411         (normal)  $2='objects' ;;
6412         (debug)   $2='obj_g' ;;
6413         (profile) $2='obj_p' ;;
6414         (shared)
6415                 case "$cf_cv_system_name" in
6416                 (cygwin|msys)
6417                         $2='objects' ;;
6418                 (*)
6419                         $2='obj_s' ;;
6420                 esac
6421         esac
6422 ])dnl
6423 dnl ---------------------------------------------------------------------------
6424 dnl CF_OUTPUT_MANPAGE_RENAMES version: 2 updated: 2022/10/22 19:12:31
6425 dnl -------------------------
6426 dnl This runs in the output step to config.status, after man_db.renames has
6427 dnl been generated.
6428 AC_DEFUN([CF_OUTPUT_MANPAGE_RENAMES],
6429 [
6430 AC_REQUIRE([CF_MANPAGE_RENAMES])
6431 if test "$MANPAGE_RENAMES" != no ; then
6432         # Construct a sed-script to perform renaming within man-pages
6433         test -n "$verbose" && echo "creating edit_man.sed"
6434         test ! -d man && mkdir man
6435         FGREP="${FGREP-grep -F}" $SHELL "$srcdir/man/make_sed.sh" "$MANPAGE_RENAMES" >./edit_man.sed
6436 fi
6437 ])dnl
6438 dnl ---------------------------------------------------------------------------
6439 dnl CF_PATHSEP version: 8 updated: 2021/01/01 13:31:04
6440 dnl ----------
6441 dnl Provide a value for the $PATH and similar separator (or amend the value
6442 dnl as provided in autoconf 2.5x).
6443 AC_DEFUN([CF_PATHSEP],
6444 [
6445         AC_MSG_CHECKING(for PATH separator)
6446         case "$cf_cv_system_name" in
6447         (os2*)  PATH_SEPARATOR=';'  ;;
6448         (*)     ${PATH_SEPARATOR:=':'}  ;;
6449         esac
6450 ifelse([$1],,,[$1=$PATH_SEPARATOR])
6451         AC_SUBST(PATH_SEPARATOR)
6452         AC_MSG_RESULT($PATH_SEPARATOR)
6453 ])dnl
6454 dnl ---------------------------------------------------------------------------
6455 dnl CF_PATH_PROG version: 12 updated: 2021/01/02 09:31:20
6456 dnl ------------
6457 dnl Check for a given program, defining corresponding symbol.
6458 dnl     $1 = environment variable, which is suffixed by "_PATH" in the #define.
6459 dnl     $2 = program name to find.
6460 dnl     $3 = optional list of additional program names to test.
6461 dnl $4 = $PATH
6462 dnl
6463 dnl If there is more than one token in the result, #define the remaining tokens
6464 dnl to $1_ARGS.  We need this for 'install' in particular.
6465 dnl
6466 dnl FIXME: we should allow this to be overridden by environment variables
6467 dnl
6468 AC_DEFUN([CF_PATH_PROG],[
6469 AC_REQUIRE([CF_PATHSEP])
6470 test -z "[$]$1" && $1="$2"
6471 AC_PATH_PROGS($1,[$]$1 $2 ifelse($3,,,$3),[$]$1, ifelse($4,,,$4))
6472
6473 cf_path_prog=""
6474 cf_path_args=""
6475 IFS="${IFS:-    }"; cf_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR"
6476 for cf_temp in $ac_cv_path_$1
6477 do
6478         if test -z "$cf_path_prog" ; then
6479                 if test "$with_full_paths" = yes ; then
6480                         CF_PATH_SYNTAX(cf_temp,break)
6481                         cf_path_prog="$cf_temp"
6482                 else
6483                         cf_path_prog="`basename "$cf_temp"`"
6484                 fi
6485         elif test -z "$cf_path_args" ; then
6486                 cf_path_args="$cf_temp"
6487         else
6488                 cf_path_args="$cf_path_args $cf_temp"
6489         fi
6490 done
6491 IFS="$cf_save_ifs"
6492
6493 if test -n "$cf_path_prog" ; then
6494         CF_MSG_LOG(defining path for ${cf_path_prog})
6495         AC_DEFINE_UNQUOTED($1_PATH,"$cf_path_prog",Define to pathname $1)
6496         test -n "$cf_path_args" && AC_DEFINE_UNQUOTED($1_ARGS,"$cf_path_args",Define to provide args for $1)
6497 fi
6498 ])dnl
6499 dnl ---------------------------------------------------------------------------
6500 dnl CF_PATH_SYNTAX version: 18 updated: 2020/12/31 18:40:20
6501 dnl --------------
6502 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
6503 dnl begins with one of the prefix/exec_prefix variables, and then again if the
6504 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
6505 dnl delayed evaluation of those symbols.
6506 AC_DEFUN([CF_PATH_SYNTAX],[
6507 if test "x$prefix" != xNONE; then
6508         cf_path_syntax="$prefix"
6509 else
6510         cf_path_syntax="$ac_default_prefix"
6511 fi
6512
6513 case ".[$]$1" in
6514 (.\[$]\(*\)*|.\'*\'*)
6515         ;;
6516 (..|./*|.\\*)
6517         ;;
6518 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
6519         ;;
6520 (.\[$]\{*prefix\}*|.\[$]\{*dir\}*)
6521         eval $1="[$]$1"
6522         case ".[$]$1" in
6523         (.NONE/*)
6524                 $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
6525                 ;;
6526         esac
6527         ;;
6528 (.no|.NONE/*)
6529         $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
6530         ;;
6531 (*)
6532         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
6533         ;;
6534 esac
6535 ])dnl
6536 dnl ---------------------------------------------------------------------------
6537 dnl CF_PKG_CONFIG version: 12 updated: 2021/10/10 20:18:09
6538 dnl -------------
6539 dnl Check for the package-config program, unless disabled by command-line.
6540 dnl
6541 dnl Sets $PKG_CONFIG to the pathname of the pkg-config program.
6542 AC_DEFUN([CF_PKG_CONFIG],
6543 [
6544 AC_MSG_CHECKING(if you want to use pkg-config)
6545 AC_ARG_WITH(pkg-config,
6546         [  --with-pkg-config{=path} enable/disable use of pkg-config],
6547         [cf_pkg_config=$withval],
6548         [cf_pkg_config=yes])
6549 AC_MSG_RESULT($cf_pkg_config)
6550
6551 case "$cf_pkg_config" in
6552 (no)
6553         PKG_CONFIG=none
6554         ;;
6555 (yes)
6556         CF_ACVERSION_CHECK(2.52,
6557                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
6558                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
6559         ;;
6560 (*)
6561         PKG_CONFIG=$withval
6562         ;;
6563 esac
6564
6565 test -z "$PKG_CONFIG" && PKG_CONFIG=none
6566 if test "$PKG_CONFIG" != none ; then
6567         CF_PATH_SYNTAX(PKG_CONFIG)
6568 elif test "x$cf_pkg_config" != xno ; then
6569         AC_MSG_WARN(pkg-config is not installed)
6570 fi
6571
6572 AC_SUBST(PKG_CONFIG)
6573 ])dnl
6574 dnl ---------------------------------------------------------------------------
6575 dnl CF_POSIX_C_SOURCE version: 11 updated: 2018/12/31 20:46:17
6576 dnl -----------------
6577 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
6578 dnl
6579 dnl     POSIX.1-1990                            _POSIX_SOURCE
6580 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
6581 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
6582 dnl             Bindings Option
6583 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
6584 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
6585 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
6586 dnl
6587 dnl Parameters:
6588 dnl     $1 is the nominal value for _POSIX_C_SOURCE
6589 AC_DEFUN([CF_POSIX_C_SOURCE],
6590 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
6591
6592 if test "$cf_cv_posix_visible" = no; then
6593
6594 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
6595
6596 cf_save_CFLAGS="$CFLAGS"
6597 cf_save_CPPFLAGS="$CPPFLAGS"
6598
6599 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
6600 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
6601
6602 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
6603         CF_MSG_LOG(if the symbol is already defined go no further)
6604         AC_TRY_COMPILE([#include <sys/types.h>],[
6605 #ifndef _POSIX_C_SOURCE
6606 make an error
6607 #endif],
6608         [cf_cv_posix_c_source=no],
6609         [cf_want_posix_source=no
6610          case .$cf_POSIX_C_SOURCE in
6611          (.[[12]]??*)
6612                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
6613                 ;;
6614          (.2)
6615                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
6616                 cf_want_posix_source=yes
6617                 ;;
6618          (.*)
6619                 cf_want_posix_source=yes
6620                 ;;
6621          esac
6622          if test "$cf_want_posix_source" = yes ; then
6623                 AC_TRY_COMPILE([#include <sys/types.h>],[
6624 #ifdef _POSIX_SOURCE
6625 make an error
6626 #endif],[],
6627                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
6628          fi
6629          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
6630          CFLAGS="$cf_trim_CFLAGS"
6631          CPPFLAGS="$cf_trim_CPPFLAGS"
6632          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
6633          CF_MSG_LOG(if the second compile does not leave our definition intact error)
6634          AC_TRY_COMPILE([#include <sys/types.h>],[
6635 #ifndef _POSIX_C_SOURCE
6636 make an error
6637 #endif],,
6638          [cf_cv_posix_c_source=no])
6639          CFLAGS="$cf_save_CFLAGS"
6640          CPPFLAGS="$cf_save_CPPFLAGS"
6641         ])
6642 ])
6643
6644 if test "$cf_cv_posix_c_source" != no ; then
6645         CFLAGS="$cf_trim_CFLAGS"
6646         CPPFLAGS="$cf_trim_CPPFLAGS"
6647         CF_ADD_CFLAGS($cf_cv_posix_c_source)
6648 fi
6649
6650 fi # cf_cv_posix_visible
6651
6652 ])dnl
6653 dnl ---------------------------------------------------------------------------
6654 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
6655 dnl ----------------
6656 dnl POSIX documents test-macros which an application may set before any system
6657 dnl headers are included to make features available.
6658 dnl
6659 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
6660 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
6661 dnl recent features visible in the system header files unless the application
6662 dnl overrides the corresponding test-macros.  Doing that introduces portability
6663 dnl problems.
6664 dnl
6665 dnl This macro makes a special check for the symbols used for this, to avoid a
6666 dnl conflicting definition.
6667 AC_DEFUN([CF_POSIX_VISIBLE],
6668 [
6669 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
6670 AC_TRY_COMPILE([#include <stdio.h>],[
6671 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
6672         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
6673         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
6674         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
6675 #error conflicting symbols found
6676 #endif
6677 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
6678 ])
6679 ])dnl
6680 dnl ---------------------------------------------------------------------------
6681 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
6682 dnl ------------
6683 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
6684 dnl
6685 dnl $1 = symbol to test
6686 dnl $2 = value (if any) to use for a predefinition
6687 AC_DEFUN([CF_PREDEFINE],
6688 [
6689 AC_MSG_CHECKING(if we must define $1)
6690 AC_TRY_COMPILE([#include <sys/types.h>
6691 ],[
6692 #ifndef $1
6693 make an error
6694 #endif],[cf_result=no],[cf_result=yes])
6695 AC_MSG_RESULT($cf_result)
6696
6697 if test "$cf_result" = yes ; then
6698         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
6699 elif test "x$2" != "x" ; then
6700         AC_MSG_CHECKING(checking for compatible value versus $2)
6701         AC_TRY_COMPILE([#include <sys/types.h>
6702 ],[
6703 #if $1-$2 < 0
6704 make an error
6705 #endif],[cf_result=yes],[cf_result=no])
6706         AC_MSG_RESULT($cf_result)
6707         if test "$cf_result" = no ; then
6708                 # perhaps we can override it - try...
6709                 CPPFLAGS="$CPPFLAGS -D$1=$2"
6710         fi
6711 fi
6712 ])dnl
6713 dnl ---------------------------------------------------------------------------
6714 dnl CF_PRG_RULES version: 2 updated: 2021/01/01 13:31:04
6715 dnl ------------
6716 dnl Append definitions and rules for the given programs to the subdirectory
6717 dnl Makefiles, and the recursion rule for the top-level Makefile.
6718 dnl
6719 dnl parameters
6720 dnl     $1 = script to run
6721 dnl     $2 = list of subdirectories
6722 dnl
6723 dnl variables
6724 dnl     $AWK
6725 AC_DEFUN([CF_PRG_RULES],
6726 [
6727 for cf_dir in $2
6728 do
6729         if test ! -d "$srcdir/$cf_dir" ; then
6730                 continue
6731         elif test -f "$srcdir/$cf_dir/programs" ; then
6732                 $AWK -f $1 "$srcdir/$cf_dir/programs" >>$cf_dir/Makefile
6733         fi
6734 done
6735
6736 ])dnl
6737 dnl ---------------------------------------------------------------------------
6738 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
6739 dnl ----------
6740 dnl Check for archiver "ar".
6741 AC_DEFUN([CF_PROG_AR],[
6742 AC_CHECK_TOOL(AR, ar, ar)
6743 ])
6744 dnl ---------------------------------------------------------------------------
6745 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
6746 dnl -----------
6747 dnl Check for awk, ensure that the check found something.
6748 AC_DEFUN([CF_PROG_AWK],
6749 [
6750 AC_PROG_AWK
6751 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
6752 ])dnl
6753 dnl ---------------------------------------------------------------------------
6754 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
6755 dnl ----------
6756 dnl standard check for CC, plus followup sanity checks
6757 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
6758 AC_DEFUN([CF_PROG_CC],[
6759 CF_ACVERSION_CHECK(2.53,
6760         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
6761          AC_REQUIRE([AC_PROG_CC])],
6762         [])
6763 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
6764 CF_GCC_VERSION
6765 CF_ACVERSION_CHECK(2.52,
6766         [AC_PROG_CC_STDC],
6767         [CF_ANSI_CC_REQD])
6768 CF_CC_ENV_FLAGS
6769 ])dnl
6770 dnl ---------------------------------------------------------------------------
6771 dnl CF_PROG_CC_C_O version: 6 updated: 2021/01/01 13:31:04
6772 dnl --------------
6773 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
6774 dnl the output file can be renamed, and allows for a shell variable that can
6775 dnl be used later.  The parameter is either CC or CXX.  The result is the
6776 dnl cache variable:
6777 dnl     $cf_cv_prog_CC_c_o
6778 dnl     $cf_cv_prog_CXX_c_o
6779 dnl
6780 dnl $1 = compiler
6781 dnl $2 = compiler options, if any
6782 AC_DEFUN([CF_PROG_CC_C_O],
6783 [AC_REQUIRE([AC_PROG_CC])dnl
6784 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
6785 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
6786 [
6787 cat > conftest.$ac_ext <<CF_EOF
6788 int main(void)
6789 {
6790         ${cf_cv_main_return:-return}(0);
6791 }
6792 CF_EOF
6793 # We do the test twice because some compilers refuse to overwrite an
6794 # existing .o file with -o, though they will create one.
6795 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
6796 if AC_TRY_EVAL(ac_try) &&
6797   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
6798 then
6799   eval cf_cv_prog_$1_c_o=yes
6800 else
6801   eval cf_cv_prog_$1_c_o=no
6802 fi
6803 rm -rf ./conftest*
6804 ])dnl
6805 if test "$cf_cv_prog_$1_c_o" = yes; then
6806   AC_MSG_RESULT([yes])
6807 else
6808   AC_MSG_RESULT([no])
6809 fi
6810 ])dnl
6811 dnl ---------------------------------------------------------------------------
6812 dnl CF_PROG_GNAT version: 12 updated: 2021/01/02 17:09:14
6813 dnl ------------
6814 dnl Check for gnat/gnatmake/etc, ensure that the toolset is complete.
6815 AC_DEFUN([CF_PROG_GNAT],[
6816 for cf_prog_gnat in gnat gnatmake gprconfig gprbuild
6817 do
6818         CF_UPPER(cf_upper_prog_gnat,${cf_prog_gnat})
6819
6820         unset ac_cv_path_cf_TEMP_gnat
6821         unset cf_TEMP_gnat
6822         AC_PATH_PROG(cf_TEMP_gnat,$cf_prog_gnat,no)
6823         eval "cf_cv_PATH_$cf_upper_prog_gnat=[$]ac_cv_path_cf_TEMP_gnat"
6824
6825         if test "x$cf_TEMP_gnat" != xno; then
6826                 unset cf_cv_gnat_version
6827                 unset cf_TEMP_gnat
6828                 CF_GNAT_VERSION(cf_TEMP_gnat,$cf_prog_gnat)
6829         fi
6830         eval "cf_cv_VERSION_$cf_upper_prog_gnat=[$]cf_TEMP_gnat"
6831
6832         unset cf_TEMP_gnat
6833         unset cf_cv_gnat_version
6834         unset ac_cv_path_cf_TEMP_gnat
6835 done
6836
6837 if test "x$cf_cv_VERSION_GNATMAKE" = "xno"; then
6838         cf_ada_make=
6839         cf_cv_prog_gnat_correct=no
6840 else
6841         cf_ada_make=gnatmake
6842         if test "x$cf_cv_VERSION_GPRCONFIG" = "xno"; then
6843                 # gprconfig is newer than gnatmake; we can continue...
6844                 cf_ada_config="##"
6845         else
6846                 rm -rf ./conftest* ./*~conftest*
6847                 if mkdir conftest.src
6848                 then
6849                         cf_ada_config=""
6850                         cd conftest.src
6851                         for cf_gprconfig in Ada C
6852                         do
6853                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
6854                                 if test "$cf_gprconfig" = C
6855                                 then
6856                                         for cf_gprconfig_param in \
6857                                                 "$cf_gprconfig,,,,GNATGCC" \
6858                                                 "$cf_gprconfig,,,,GCC" \
6859                                                 "$cf_gprconfig"
6860                                         do
6861                                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6862                                                 test -n "$cf_gprconfig_value" && break
6863                                         done
6864                                 else
6865                                         cf_gprconfig_param=$cf_gprconfig
6866                                         cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6867                                 fi
6868                                 if test -n "$cf_gprconfig_value"
6869                                 then
6870                                         eval "cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value"
6871                                         AC_MSG_RESULT($cf_gprconfig_value)
6872                                 else
6873                                         AC_MSG_RESULT(missing)
6874                                         cf_ada_config="#"
6875                                         break
6876                                 fi
6877                         done
6878                         cd ..
6879                         rm -rf ./conftest* ./*~conftest*
6880                 fi
6881         fi
6882         if test "x$cf_ada_config" != "x#"
6883         then
6884                 CF_GNAT_VERSION
6885                 CF_CHECK_GNAT_VERSION
6886                 AC_CHECK_PROG(M4_exists, m4, yes, no)
6887                 if test "$ac_cv_prog_M4_exists" = no; then
6888                         cf_cv_prog_gnat_correct=no
6889                         AC_MSG_WARN(Ada95 binding required program m4 not found. Ada95 binding disabled)
6890                 fi
6891                 if test "$cf_cv_prog_gnat_correct" = yes; then
6892                         AC_MSG_CHECKING(if GNAT works)
6893                         CF_GNAT_TRY_RUN([procedure conftest;],
6894 [with Text_IO;
6895 with GNAT.OS_Lib;
6896 procedure conftest is
6897 begin
6898    Text_IO.Put ("Hello World");
6899    Text_IO.New_Line;
6900    GNAT.OS_Lib.OS_Exit (0);
6901 end conftest;],
6902 [cf_cv_prog_gnat_correct=yes],
6903 [cf_cv_prog_gnat_correct=no])
6904                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
6905                 fi
6906         else
6907                 cf_cv_prog_gnat_correct=no
6908         fi
6909 fi
6910
6911 AC_SUBST(cf_ada_make)
6912 AC_SUBST(cf_ada_config)
6913 AC_SUBST(cf_ada_config_Ada)
6914 AC_SUBST(cf_ada_config_C)
6915 ])dnl
6916 dnl ---------------------------------------------------------------------------
6917 dnl CF_PROG_INSTALL version: 10 updated: 2021/01/04 19:33:05
6918 dnl ---------------
6919 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
6920 dnl misc/tabset install won't work properly.  Usually this happens only when
6921 dnl using the fallback mkinstalldirs script
6922 AC_DEFUN([CF_PROG_INSTALL],
6923 [AC_PROG_INSTALL
6924 case $INSTALL in
6925 (/*)
6926         ;;
6927 (*)
6928         CF_DIRNAME(cf_dir,$INSTALL)
6929         test -z "$cf_dir" && cf_dir=.
6930         INSTALL="`cd \"$cf_dir\" && pwd`"/"`echo "$INSTALL" | sed -e 's%^.*/%%'`"
6931         ;;
6932 esac
6933 ])dnl
6934 dnl ---------------------------------------------------------------------------
6935 dnl CF_PROG_LDCONFIG version: 5 updated: 2015/04/18 08:56:57
6936 dnl ----------------
6937 dnl Check for ldconfig, needed to fixup shared libraries that would be built
6938 dnl and then used in the install.
6939 AC_DEFUN([CF_PROG_LDCONFIG],[
6940 if test "$cross_compiling" = yes ; then
6941         LDCONFIG=:
6942 else
6943         case "$cf_cv_system_name" in
6944         (dragonfly*|mirbsd*|freebsd*)
6945                 test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
6946                 ;;
6947         (*) LDPATH=$PATH:/sbin:/usr/sbin
6948                 AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
6949                 ;;
6950         esac
6951 fi
6952 AC_SUBST(LDCONFIG)
6953 ])dnl
6954 dnl ---------------------------------------------------------------------------
6955 dnl CF_PROG_LINT version: 5 updated: 2022/08/20 15:44:13
6956 dnl ------------
6957 AC_DEFUN([CF_PROG_LINT],
6958 [
6959 AC_CHECK_PROGS(LINT, lint cppcheck splint)
6960 case "x$LINT" in
6961 (xcppcheck|x*/cppcheck)
6962         test -z "$LINT_OPTS" && LINT_OPTS="--enable=all"
6963         ;;
6964 esac
6965 AC_SUBST(LINT_OPTS)
6966 AC_SUBST(LINT_LIBS)
6967 ])dnl
6968 dnl ---------------------------------------------------------------------------
6969 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
6970 dnl ------------
6971 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
6972 dnl option if it is supported.
6973 AC_DEFUN([CF_PROG_LN_S],[
6974 AC_PROG_LN_S
6975 AC_MSG_CHECKING(if $LN_S -f options work)
6976
6977 rm -f conf$$.src conf$$dst
6978 echo >conf$$.dst
6979 echo first >conf$$.src
6980 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
6981         cf_prog_ln_sf=yes
6982 else
6983         cf_prog_ln_sf=no
6984 fi
6985 rm -f conf$$.dst conf$$src
6986 AC_MSG_RESULT($cf_prog_ln_sf)
6987
6988 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
6989 ])dnl
6990 dnl ---------------------------------------------------------------------------
6991 dnl CF_REGEX version: 18 updated: 2021/01/01 16:53:59
6992 dnl --------
6993 dnl Attempt to determine if we've got one of the flavors of regular-expression
6994 dnl code that we can support.
6995 AC_DEFUN([CF_REGEX],
6996 [
6997
6998 cf_regex_func=no
6999 cf_regex_libs=
7000 case "$host_os" in
7001 (mingw*)
7002         # -lsystre -ltre -lintl -liconv
7003         AC_CHECK_LIB(systre,regcomp,[
7004                 AC_CHECK_LIB(iconv,libiconv_open,[CF_ADD_LIB(iconv)])
7005                 AC_CHECK_LIB(intl,libintl_gettext,[CF_ADD_LIB(intl)])
7006                 AC_CHECK_LIB(tre,tre_regcomp,[CF_ADD_LIB(tre)])
7007                 CF_ADD_LIB(systre)
7008                 cf_regex_func=regcomp
7009         ],[
7010                 AC_CHECK_LIB(gnurx,regcomp,[
7011                         CF_ADD_LIB(gnurx)
7012                         cf_regex_func=regcomp])
7013         ])
7014         ;;
7015 (*)
7016         cf_regex_libs="regex re"
7017         AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
7018                 for cf_regex_lib in $cf_regex_libs
7019                 do
7020                         AC_CHECK_LIB($cf_regex_lib,regcomp,[
7021                                         CF_ADD_LIB($cf_regex_lib)
7022                                         cf_regex_func=regcomp
7023                                         break])
7024                 done
7025         ])
7026         ;;
7027 esac
7028
7029 if test "$cf_regex_func" = no ; then
7030         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
7031                 AC_CHECK_LIB(gen,compile,[
7032                                 CF_ADD_LIB(gen)
7033                                 cf_regex_func=compile])])
7034 fi
7035
7036 if test "$cf_regex_func" = no ; then
7037         AC_MSG_WARN(cannot find regular expression library)
7038 fi
7039
7040 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
7041
7042 cf_cv_regex_hdrs=no
7043 case "$cf_regex_func" in
7044 (compile)
7045         for cf_regex_hdr in regexp.h regexpr.h
7046         do
7047                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
7048                         char *p = compile("", "", "", 0);
7049                         int x = step("", "");
7050                         (void)p;
7051                         (void)x;
7052                 ],[
7053                         cf_cv_regex_hdrs=$cf_regex_hdr
7054                         break
7055                 ])
7056         done
7057         ;;
7058 (*)
7059         for cf_regex_hdr in regex.h
7060         do
7061                 AC_TRY_LINK([#include <sys/types.h>
7062 #include <$cf_regex_hdr>],[
7063                         regex_t *p = 0;
7064                         int x = regcomp(p, "", 0);
7065                         int y = regexec(p, "", 0, 0, 0);
7066                         (void)x;
7067                         (void)y;
7068                         regfree(p);
7069                 ],[
7070                         cf_cv_regex_hdrs=$cf_regex_hdr
7071                         break
7072                 ])
7073         done
7074         ;;
7075 esac
7076
7077 ])
7078
7079 case "$cf_cv_regex_hdrs" in
7080         (no)            AC_MSG_WARN(no regular expression header found) ;;
7081         (regex.h)       AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;;
7082         (regexp.h)      AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;;
7083         (regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
7084 esac
7085 ])dnl
7086 dnl ---------------------------------------------------------------------------
7087 dnl CF_REMOVE_CFLAGS version: 3 updated: 2021/09/05 17:25:40
7088 dnl ----------------
7089 dnl Remove a given option from CFLAGS/CPPFLAGS
7090 dnl $1 = option to remove
7091 dnl $2 = variable to update
7092 dnl $3 = nonempty to allow verbose message
7093 define([CF_REMOVE_CFLAGS],
7094 [
7095 cf_tmp_cflag=`echo "x$1" | sed -e 's/^.//' -e 's/=.*//'`
7096 while true
7097 do
7098         cf_old_cflag=`echo "x[$]$2" | sed -e 's/^.//' -e 's/[[  ]][[    ]]*-/ -/g' -e "s%$cf_tmp_cflag\\(=[[^   ]][[^   ]]*\\)\?%%" -e 's/^[[   ]]*//' -e 's%[[ ]][[ ]]*-D% -D%g' -e 's%[[ ]][[ ]]*-I% -I%g'`
7099         test "[$]$2" != "$cf_old_cflag" || break
7100         ifelse([$3],,,[CF_VERBOSE(removing old option $1 from $2)])
7101         $2="$cf_old_cflag"
7102 done
7103 ])dnl
7104 dnl ---------------------------------------------------------------------------
7105 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
7106 dnl ----------------
7107 dnl Remove all -U and -D options that refer to the given symbol from a list
7108 dnl of C compiler options.  This works around the problem that not all
7109 dnl compilers process -U and -D options from left-to-right, so a -U option
7110 dnl cannot be used to cancel the effect of a preceding -D option.
7111 dnl
7112 dnl $1 = target (which could be the same as the source variable)
7113 dnl $2 = source (including '$')
7114 dnl $3 = symbol to remove
7115 define([CF_REMOVE_DEFINE],
7116 [
7117 $1=`echo "$2" | \
7118         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
7119                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
7120 ])dnl
7121 dnl ---------------------------------------------------------------------------
7122 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
7123 dnl -------------
7124 dnl Remove the given library from the symbol
7125 dnl
7126 dnl $1 = target (which could be the same as the source variable)
7127 dnl $2 = source (including '$')
7128 dnl $3 = library to remove
7129 define([CF_REMOVE_LIB],
7130 [
7131 # remove $3 library from $2
7132 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
7133 ])dnl
7134 dnl ---------------------------------------------------------------------------
7135 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
7136 dnl ---------------------
7137 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
7138 dnl $1 = name of current macro
7139 define([CF_RESTORE_XTRA_FLAGS],
7140 [
7141 LIBS="$cf_save_LIBS_$1"
7142 CFLAGS="$cf_save_CFLAGS_$1"
7143 CPPFLAGS="$cf_save_CPPFLAGS_$1"
7144 ])dnl
7145 dnl ---------------------------------------------------------------------------
7146 dnl CF_RPATH_HACK version: 13 updated: 2021/01/03 18:30:50
7147 dnl -------------
7148 AC_DEFUN([CF_RPATH_HACK],
7149 [AC_REQUIRE([AC_PROG_FGREP])dnl
7150 AC_REQUIRE([CF_LD_RPATH_OPT])dnl
7151
7152 AC_MSG_CHECKING(for updated LDFLAGS)
7153 if test -n "$LD_RPATH_OPT" ; then
7154         AC_MSG_RESULT(maybe)
7155
7156         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
7157         cf_rpath_list="/usr/lib /lib"
7158         if test "$cf_ldd_prog" != no
7159         then
7160                 cf_rpath_oops=
7161
7162 AC_TRY_LINK([#include <stdio.h>],
7163                 [printf("Hello");],
7164                 [cf_rpath_oops=`"$cf_ldd_prog" "conftest$ac_exeext" | ${FGREP-fgrep} ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
7165                  cf_rpath_list=`"$cf_ldd_prog" "conftest$ac_exeext" | ${FGREP-fgrep} / | sed -e 's%^.*[[        ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
7166
7167                 # If we passed the link-test, but get a "not found" on a given library,
7168                 # this could be due to inept reconfiguration of gcc to make it only
7169                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
7170                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
7171                 # /usr/local libraries.
7172                 if test -n "$cf_rpath_oops"
7173                 then
7174                         for cf_rpath_src in $cf_rpath_oops
7175                         do
7176                                 for cf_rpath_dir in \
7177                                         /usr/local \
7178                                         /usr/pkg \
7179                                         /opt/sfw
7180                                 do
7181                                         if test -f "$cf_rpath_dir/lib/$cf_rpath_src"
7182                                         then
7183                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
7184                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
7185                                                 break
7186                                         fi
7187                                 done
7188                         done
7189                 fi
7190         fi
7191
7192         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
7193
7194         CF_RPATH_HACK_2(LDFLAGS)
7195         CF_RPATH_HACK_2(LIBS)
7196
7197         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
7198 else
7199         AC_MSG_RESULT(no)
7200 fi
7201 AC_SUBST(EXTRA_LDFLAGS)
7202 ])dnl
7203 dnl ---------------------------------------------------------------------------
7204 dnl CF_RPATH_HACK_2 version: 8 updated: 2021/01/01 13:31:04
7205 dnl ---------------
7206 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
7207 dnl EXTRA_LDFLAGS for each -L option found.
7208 dnl
7209 dnl $cf_rpath_list contains a list of directories to ignore.
7210 dnl
7211 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
7212 dnl      but LIBS often has misplaced -L options.
7213 AC_DEFUN([CF_RPATH_HACK_2],
7214 [
7215 CF_VERBOSE(...checking $1 [$]$1)
7216
7217 cf_rpath_dst=
7218 for cf_rpath_src in [$]$1
7219 do
7220         case "$cf_rpath_src" in
7221         (-L*)
7222
7223                 # check if this refers to a directory which we will ignore
7224                 cf_rpath_skip=no
7225                 if test -n "$cf_rpath_list"
7226                 then
7227                         for cf_rpath_item in $cf_rpath_list
7228                         do
7229                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
7230                                 then
7231                                         cf_rpath_skip=yes
7232                                         break
7233                                 fi
7234                         done
7235                 fi
7236
7237                 if test "$cf_rpath_skip" = no
7238                 then
7239                         # transform the option
7240                         if test "$LD_RPATH_OPT" = "-R " ; then
7241                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
7242                         else
7243                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
7244                         fi
7245
7246                         # if we have not already added this, add it now
7247                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
7248                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
7249                         then
7250                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
7251                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
7252                         fi
7253                 fi
7254                 ;;
7255         esac
7256         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
7257 done
7258 $1=$cf_rpath_dst
7259
7260 CF_VERBOSE(...checked $1 [$]$1)
7261 AC_SUBST(EXTRA_LDFLAGS)
7262 ])dnl
7263 dnl ---------------------------------------------------------------------------
7264 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
7265 dnl ------------------
7266 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
7267 dnl and libraries which do not update those variables.
7268 dnl
7269 dnl $1 = name of current macro
7270 define([CF_SAVE_XTRA_FLAGS],
7271 [
7272 cf_save_LIBS_$1="$LIBS"
7273 cf_save_CFLAGS_$1="$CFLAGS"
7274 cf_save_CPPFLAGS_$1="$CPPFLAGS"
7275 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
7276 for cf_X_CFLAGS in $X_CFLAGS
7277 do
7278         case "x$cf_X_CFLAGS" in
7279         x-[[IUD]]*)
7280                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
7281                 ;;
7282         *)
7283                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
7284                 ;;
7285         esac
7286 done
7287 ])dnl
7288 dnl ---------------------------------------------------------------------------
7289 dnl CF_SHARED_OPTS version: 107 updated: 2021/09/04 06:47:34
7290 dnl --------------
7291 dnl --------------
7292 dnl Attempt to determine the appropriate CC/LD options for creating a shared
7293 dnl library.
7294 dnl
7295 dnl Notes:
7296 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
7297 dnl the build-tree, i.e., by making use of the libraries that are compiled in
7298 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
7299 dnl shared library since that can lead to unexpected results at runtime.
7300 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
7301 dnl libraries are compiled in ../../lib
7302 dnl
7303 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
7304 dnl to install symbolic links to the rel/abi versions of shared libraries.
7305 dnl
7306 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
7307 dnl version when making symbolic links.
7308 dnl
7309 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
7310 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
7311 dnl (ex: libncurses.so.<ver>).
7312 dnl
7313 dnl Some loaders leave 'so_locations' lying around.  It is nice to clean up.
7314 AC_DEFUN([CF_SHARED_OPTS],
7315 [
7316         AC_REQUIRE([CF_LD_RPATH_OPT])
7317
7318         RM_SHARED_OPTS=
7319         LOCAL_LDFLAGS=
7320         LOCAL_LDFLAGS2=
7321         LD_SHARED_OPTS=
7322         INSTALL_LIB="-m 644"
7323         : ${rel_builddir:=.}
7324
7325         shlibdir=$libdir
7326         AC_SUBST(shlibdir)
7327
7328         MAKE_DLLS="#"
7329         AC_SUBST(MAKE_DLLS)
7330
7331         cf_cv_do_symlinks=no
7332         cf_ld_rpath_opt=
7333         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
7334
7335         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
7336         AC_ARG_WITH(shlib-version,
7337         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
7338         [test -z "$withval" && withval=auto
7339         case "$withval" in
7340         (yes)
7341                 cf_cv_shlib_version=auto
7342                 ;;
7343         (rel|abi|auto)
7344                 cf_cv_shlib_version=$withval
7345                 ;;
7346         (*)
7347                 AC_MSG_RESULT($withval)
7348                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
7349                 ;;
7350         esac
7351         ],[cf_cv_shlib_version=auto])
7352         AC_MSG_RESULT($cf_cv_shlib_version)
7353
7354         cf_cv_rm_so_locs=no
7355         cf_try_cflags=
7356
7357         # Some less-capable ports of gcc support only -fpic
7358         CC_SHARED_OPTS=
7359
7360         cf_try_fPIC=no
7361         if test "$GCC" = yes
7362         then
7363                 cf_try_fPIC=yes
7364         else
7365                 case "$cf_cv_system_name" in
7366                 (*linux*)       # e.g., PGI compiler
7367                         cf_try_fPIC=yes
7368                         ;;
7369                 esac
7370         fi
7371
7372         if test "$cf_try_fPIC" = yes
7373         then
7374                 AC_MSG_CHECKING(which $CC option to use)
7375                 cf_save_CFLAGS="$CFLAGS"
7376                 for CC_SHARED_OPTS in -fPIC -fpic ''
7377                 do
7378                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
7379                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
7380                 done
7381                 AC_MSG_RESULT($CC_SHARED_OPTS)
7382                 CFLAGS="$cf_save_CFLAGS"
7383         fi
7384
7385         cf_cv_shlib_version_infix=no
7386
7387         case "$cf_cv_system_name" in
7388         (aix4.[3-9]*|aix[[5-7]]*)
7389                 if test "$GCC" = yes; then
7390                         CC_SHARED_OPTS='-Wl,-brtl'
7391                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
7392                 else
7393                         CC_SHARED_OPTS='-brtl'
7394                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
7395                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
7396                 fi
7397                 ;;
7398         (beos*)
7399                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
7400                 ;;
7401         (cygwin*)
7402                 CC_SHARED_OPTS=
7403                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
7404                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
7405                 cf_cv_shlib_version=cygdll
7406                 cf_cv_shlib_version_infix=cygdll
7407                 shlibdir=$bindir
7408                 MAKE_DLLS=
7409                 cat >mk_shared_lib.sh <<-CF_EOF
7410                 #!$SHELL
7411                 SHARED_LIB=\[$]1
7412                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
7413                 shift
7414                 cat <<-EOF
7415                 Linking shared library
7416                 ** SHARED_LIB \[$]SHARED_LIB
7417                 ** IMPORT_LIB \[$]IMPORT_LIB
7418 EOF
7419                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7420 CF_EOF
7421                 chmod +x mk_shared_lib.sh
7422                 ;;
7423         (msys*)
7424                 CC_SHARED_OPTS=
7425                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
7426                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
7427                 cf_cv_shlib_version=msysdll
7428                 cf_cv_shlib_version_infix=msysdll
7429                 shlibdir=$bindir
7430                 MAKE_DLLS=
7431                 cat >mk_shared_lib.sh <<-CF_EOF
7432                 #!$SHELL
7433                 SHARED_LIB=\[$]1
7434                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
7435                 shift
7436                 cat <<-EOF
7437                 Linking shared library
7438                 ** SHARED_LIB \[$]SHARED_LIB
7439                 ** IMPORT_LIB \[$]IMPORT_LIB
7440 EOF
7441                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7442 CF_EOF
7443                 chmod +x mk_shared_lib.sh
7444                 ;;
7445         (darwin*)
7446                 cf_try_cflags="no-cpp-precomp"
7447                 CC_SHARED_OPTS="-dynamic"
7448                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
7449                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
7450                 cf_cv_shlib_version_infix=yes
7451                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
7452                         cf_save_LDFLAGS=$LDFLAGS
7453                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
7454                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
7455                                 LDFLAGS=$cf_save_LDFLAGS])
7456                 if test "$cf_cv_ldflags_search_paths_first" = yes; then
7457                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
7458                 fi
7459                 ;;
7460         (haiku*)
7461                 CF_SHARED_SONAME
7462                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7463                 ;;
7464         (hpux[[7-8]]*)
7465                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
7466                 if test "$GCC" != yes; then
7467                         CC_SHARED_OPTS='+Z'
7468                 fi
7469                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
7470                 INSTALL_LIB="-m 555"
7471                 ;;
7472         (hpux*)
7473                 # (tested with gcc 2.7.2 -- I don't have c89)
7474                 if test "$GCC" = yes; then
7475                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
7476                 else
7477                         CC_SHARED_OPTS='+Z'
7478                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
7479                 fi
7480                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
7481                 # HP-UX shared libraries must be executable, and should be
7482                 # readonly to exploit a quirk in the memory manager.
7483                 INSTALL_LIB="-m 555"
7484                 ;;
7485         (interix*)
7486                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7487                 if test "$cf_cv_shlib_version" = rel; then
7488                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
7489                 else
7490                         cf_shared_soname='`basename $[@]`'
7491                 fi
7492                 CC_SHARED_OPTS=
7493                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
7494                 ;;
7495         (irix*)
7496                 if test "$cf_cv_enable_rpath" = yes ; then
7497                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7498                 fi
7499                 # tested with IRIX 5.2 and 'cc'.
7500                 if test "$GCC" != yes; then
7501                         CC_SHARED_OPTS='-KPIC'
7502                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
7503                 else
7504                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
7505                 fi
7506                 cf_cv_rm_so_locs=yes
7507                 ;;
7508         (linux*|gnu*|k*bsd*-gnu)
7509                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7510                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7511                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7512                 fi
7513                 if test "$cf_cv_enable_rpath" = yes ; then
7514                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7515                 fi
7516                 CF_SHARED_SONAME
7517                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7518                 ;;
7519         (mingw*msvc*)
7520                 cf_cv_shlib_version=msvcdll
7521                 cf_cv_shlib_version_infix=msvcdll
7522                 shlibdir=$bindir
7523                 MAKE_DLLS=
7524                 if test "$DFT_LWR_MODEL" = "shared" ; then
7525                         LOCAL_LDFLAGS="-link -dll"
7526                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7527                         EXTRA_LDFLAGS="-link -dll $EXTRA_LDFLAGS"
7528                 fi
7529                 CC_SHARED_OPTS=
7530                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ ${LD} [$]{CFLAGS}'
7531                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.lib"
7532                 cat >mk_shared_lib.sh <<-CF_EOF
7533                 #!$SHELL
7534                 SHARED_LIB=\[$]1
7535                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.lib/'\`
7536                 shift
7537                 my_ld=\[$]1
7538                 shift
7539                 cat <<-EOF
7540                 Linking shared library
7541                 ** SHARED LIB \$SHARED_LIB
7542                 ** IMPORT_LIB \$IMPORT_LIB
7543 EOF
7544                 args=\$(echo \[$]* | sed -E "s#-l(\w*)#\1.dll.lib#g" | sed -E "s#-L(\w*)#-LIBPATH:\1#g")
7545                 exec \$my_ld -DLL -IMPLIB:"\${IMPORT_LIB}" -OUT:"\${SHARED_LIB}" ${LDFLAGS} \$args
7546                 mv "\${IMPORT_LIB}" "\${IMPORT_LIB}"
7547 CF_EOF
7548                 chmod +x mk_shared_lib.sh
7549                 cat >mk_prog.sh <<-CF_EOF
7550                 #!$SHELL
7551                 shift
7552                 # Ignore first argument (compiler) and use LD (link.exe) unconditionally
7553                 LD="[$]LD"
7554                 clopts=()
7555                 ldopts=("/subsystem:console")
7556                 libs=()
7557                 isdll=0
7558                 while test \[$]# -gt 0; do
7559                         case "\[$]1" in
7560                                 -link)
7561                                         # ignore -link argument
7562                                         ;;
7563                                 -M[[TD]] | -M[[TD]]d)
7564                                         # ignore runtime-library option
7565                                         ;;
7566                                 -dll)
7567                                         isdll=1
7568                                         ;;
7569                                 -W* | -w*)
7570                                         # ignore warnings
7571                                         ;;
7572                                 -D*)
7573                                         clopts+=("\[$]1")
7574                                         ;;
7575                                 -I*)
7576                                         clopts+=("\[$]1")
7577                                         ;;
7578                                 -l*)
7579                                         libs+=("\`echo \"\[$]1\" | sed \"s/^-l//\"\`")
7580                                         ;;
7581                                 -L*)
7582                                         ldopts+=("\`echo \"\[$]1\" | sed \"s/^-L/-LIBPATH:/\"\`")
7583                                         ;;
7584                                 *.obj | *.o)
7585                                         ldopts+=("\[$]1")
7586                                         ;;
7587                                 -Wl,*)
7588                                         for linkarg in \`echo '\[$]1' | sed -e 's/-Wl,//' -e 's/,/ /'\`; do
7589                                                 ldopts+=("\[$]{linkarg}")
7590                                         done
7591                                         ;;
7592                                 *.lib)
7593                                         ldopts+=("\[$]1")
7594                                         ;;
7595                                 -o)
7596                                         shift
7597                                         ldopts+=("-out:\[$]1")
7598                                         ;;
7599                                 *)
7600                                         clopts+=("\[$]1")
7601                                         ldopts+=("\[$]1")
7602                                         ;;
7603                         esac
7604                         shift
7605                 done
7606                 if [[ "\$isdll" -ne 0 ]]; then
7607                         for lib in \[$]{libs[[*]]}; do
7608                                 ldopts+=("\[$]lib.dll.lib")
7609                         done
7610                 else
7611                         for lib in \[$]{libs[[*]]}; do
7612                                 ldopts+=("\[$]lib.lib")
7613                         done
7614                 fi
7615                 cat <<-EOF
7616                 Creating program
7617                 ** ld options:   "\[$]{ldopts[[@]]}"
7618 EOF
7619                 exec \[$]LD \[$]{ldopts[[@]]}
7620 CF_EOF
7621                 chmod +x mk_prog.sh
7622                 LINK_PROGS="$SHELL ${rel_builddir}/mk_prog.sh"
7623                 LINK_TESTS="$SHELL ${rel_builddir}/mk_prog.sh"
7624                 ;;
7625         (mingw*)
7626                 cf_cv_shlib_version=mingw
7627                 cf_cv_shlib_version_infix=mingw
7628                 shlibdir=$bindir
7629                 MAKE_DLLS=
7630                 if test "$DFT_LWR_MODEL" = "shared" ; then
7631                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
7632                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7633                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
7634                 fi
7635                 CC_SHARED_OPTS=
7636                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
7637                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
7638                 cat >mk_shared_lib.sh <<-CF_EOF
7639                 #!$SHELL
7640                 SHARED_LIB=\[$]1
7641                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
7642                 shift
7643                 cat <<-EOF
7644                 Linking shared library
7645                 ** SHARED_LIB \[$]SHARED_LIB
7646                 ** IMPORT_LIB \[$]IMPORT_LIB
7647 EOF
7648                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7649 CF_EOF
7650                 chmod +x mk_shared_lib.sh
7651                 ;;
7652         (openbsd[[2-9]].*|mirbsd*)
7653                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7654                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7655                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7656                 fi
7657                 if test "$cf_cv_enable_rpath" = yes ; then
7658                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7659                 fi
7660                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7661                 CF_SHARED_SONAME
7662                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7663                 ;;
7664         (nskJ*)
7665                 CC_SHARED_OPTS=
7666                 MK_SHARED_LIB='${LD} -Wshared -Weld=-export_all -o $[@]'
7667                 ;;
7668         (nskL*)
7669                 CC_SHARED_OPTS=
7670                 MK_SHARED_LIB='${LD} -Wshared -Wxld=-export_all -o $[@]'
7671                 ;;
7672         (nto-qnx*|openbsd*|freebsd[[12]].*)
7673                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7674                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
7675                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7676                 ;;
7677         (dragonfly*|freebsd*)
7678                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7679                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
7680                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
7681                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
7682                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7683                 fi
7684                 CF_SHARED_SONAME
7685                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7686                 ;;
7687         (netbsd*)
7688                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7689                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
7690                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
7691                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7692                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7693                         if test "$cf_cv_shlib_version" = auto; then
7694                         if test -f /usr/libexec/ld.elf_so; then
7695                                 cf_cv_shlib_version=abi
7696                         else
7697                                 cf_cv_shlib_version=rel
7698                         fi
7699                         fi
7700                         CF_SHARED_SONAME
7701                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
7702                 else
7703                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -o $[@]'
7704                 fi
7705                 ;;
7706         (osf*|mls+*)
7707                 # tested with OSF/1 V3.2 and 'cc'
7708                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
7709                 # link with shared libs).
7710                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
7711                 case "$host_os" in
7712                 (osf4*)
7713                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
7714                         ;;
7715                 esac
7716                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
7717                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7718                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7719                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7720                 fi
7721                 cf_cv_rm_so_locs=yes
7722                 ;;
7723         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
7724                 # tested with osr5.0.5
7725                 if test "$GCC" != yes; then
7726                         CC_SHARED_OPTS='-belf -KPIC'
7727                 fi
7728                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
7729                 if test "$cf_cv_enable_rpath" = yes ; then
7730                         # only way is to set LD_RUN_PATH but no switch for it
7731                         RUN_PATH=$libdir
7732                 fi
7733                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7734                 LINK_PROGS='LD_RUN_PATH=${libdir}'
7735                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
7736                 ;;
7737         (sunos4*)
7738                 # tested with SunOS 4.1.1 and gcc 2.7.0
7739                 if test "$GCC" != yes; then
7740                         CC_SHARED_OPTS='-KPIC'
7741                 fi
7742                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
7743                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7744                 ;;
7745         (solaris2*)
7746                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
7747                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
7748                 if test "$DFT_LWR_MODEL" = "shared" ; then
7749                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
7750                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7751                 fi
7752                 if test "$cf_cv_enable_rpath" = yes ; then
7753                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
7754                 fi
7755                 CF_SHARED_SONAME
7756                 if test "$GCC" != yes; then
7757                         cf_save_CFLAGS="$CFLAGS"
7758                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
7759                         do
7760                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
7761                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\\n");],[break])
7762                         done
7763                         CFLAGS="$cf_save_CFLAGS"
7764                         CC_SHARED_OPTS=$cf_shared_opts
7765                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
7766                 else
7767                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
7768                 fi
7769                 ;;
7770         (sysv5uw7*|unix_sv*)
7771                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
7772                 if test "$GCC" != yes; then
7773                         CC_SHARED_OPTS='-KPIC'
7774                 fi
7775                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
7776                 ;;
7777         (*)
7778                 CC_SHARED_OPTS='unknown'
7779                 MK_SHARED_LIB='echo unknown'
7780                 ;;
7781         esac
7782
7783         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
7784         case "$cf_cv_shlib_version" in
7785         (rel|abi)
7786                 case "$MK_SHARED_LIB" in
7787                 (*'-o $[@]')
7788                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
7789                         ;;
7790                 (*)
7791                         AC_MSG_WARN(ignored --with-shlib-version)
7792                         ;;
7793                 esac
7794                 ;;
7795         esac
7796
7797         if test -n "$cf_try_cflags"
7798         then
7799 cat > conftest.$ac_ext <<EOF
7800 #line __oline__ "${as_me:-configure}"
7801 #include <stdio.h>
7802 int main(int argc, char *argv[[]])
7803 {
7804         printf("hello\\n");
7805         return (argv[[argc-1]] == 0) ;
7806 }
7807 EOF
7808                 cf_save_CFLAGS="$CFLAGS"
7809                 for cf_opt in $cf_try_cflags
7810                 do
7811                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
7812                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
7813                         if AC_TRY_EVAL(ac_compile); then
7814                                 AC_MSG_RESULT(yes)
7815                                 cf_save_CFLAGS="$CFLAGS"
7816                         else
7817                                 AC_MSG_RESULT(no)
7818                         fi
7819                 done
7820                 CFLAGS="$cf_save_CFLAGS"
7821         fi
7822
7823
7824         # RPATH_LIST is a colon-separated list of directories
7825         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
7826         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
7827
7828         test "$cf_cv_rm_so_locs" = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
7829
7830         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
7831         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7832
7833         AC_SUBST(CC_SHARED_OPTS)
7834         AC_SUBST(LD_RPATH_OPT)
7835         AC_SUBST(LD_SHARED_OPTS)
7836         AC_SUBST(MK_SHARED_LIB)
7837         AC_SUBST(RM_SHARED_OPTS)
7838
7839         AC_SUBST(LINK_PROGS)
7840         AC_SUBST(LINK_TESTS)
7841
7842         AC_SUBST(EXTRA_LDFLAGS)
7843         AC_SUBST(LOCAL_LDFLAGS)
7844         AC_SUBST(LOCAL_LDFLAGS2)
7845
7846         AC_SUBST(INSTALL_LIB)
7847         AC_SUBST(RPATH_LIST)
7848 ])dnl
7849 dnl ---------------------------------------------------------------------------
7850 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
7851 dnl ----------------
7852 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
7853 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
7854 dnl option.
7855 dnl
7856 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
7857 dnl If missing, use "rel".
7858 define([CF_SHARED_SONAME],
7859 [
7860         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
7861         if test "$cf_cv_shlib_version" = rel; then
7862                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
7863         else
7864                 cf_cv_shared_soname='`basename $[@]`'
7865         fi
7866 ])
7867 dnl ---------------------------------------------------------------------------
7868 dnl CF_SIGWINCH version: 6 updated: 2021/01/01 13:31:04
7869 dnl -----------
7870 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
7871 dnl programs need this test).
7872 dnl
7873 dnl This is really a Mac OS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
7874 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
7875 dnl winsize declaration is left alone - we may revisit this if Apple choose to
7876 dnl break that part of the interface as well.
7877 AC_DEFUN([CF_SIGWINCH],
7878 [
7879 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
7880         AC_TRY_COMPILE([
7881 #include <sys/types.h>
7882 #include <sys/signal.h>
7883 ],[int x = SIGWINCH; (void)x],
7884         [cf_cv_define_sigwinch=yes],
7885         [AC_TRY_COMPILE([
7886 #undef _XOPEN_SOURCE
7887 #undef _POSIX_SOURCE
7888 #undef _POSIX_C_SOURCE
7889 #include <sys/types.h>
7890 #include <sys/signal.h>
7891 ],[int x = SIGWINCH; (void)x],
7892         [cf_cv_define_sigwinch=maybe],
7893         [cf_cv_define_sigwinch=no])
7894 ])
7895 ])
7896
7897 if test "$cf_cv_define_sigwinch" = maybe ; then
7898 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
7899 cf_cv_fixup_sigwinch=unknown
7900 cf_sigwinch=32
7901 while test "$cf_sigwinch" != 1
7902 do
7903         AC_TRY_COMPILE([
7904 #undef _XOPEN_SOURCE
7905 #undef _POSIX_SOURCE
7906 #undef _POSIX_C_SOURCE
7907 #include <sys/types.h>
7908 #include <sys/signal.h>
7909 ],[
7910 #if SIGWINCH != $cf_sigwinch
7911 make an error
7912 #endif
7913 int x = SIGWINCH; (void)x],
7914         [cf_cv_fixup_sigwinch=$cf_sigwinch
7915          break])
7916
7917 cf_sigwinch="`expr "$cf_sigwinch" - 1`"
7918 done
7919 ])
7920
7921         if test "$cf_cv_fixup_sigwinch" != unknown ; then
7922                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
7923         fi
7924 fi
7925 ])dnl
7926 dnl ---------------------------------------------------------------------------
7927 dnl CF_SIG_ATOMIC_T version: 5 updated: 2020/03/10 18:53:47
7928 dnl ---------------
7929 dnl signal handler, but there are some gcc dependencies in that recommendation.
7930 dnl Try anyway.
7931 AC_DEFUN([CF_SIG_ATOMIC_T],
7932 [
7933 AC_MSG_CHECKING(for signal global datatype)
7934 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
7935         for cf_type in \
7936                 "volatile sig_atomic_t" \
7937                 "sig_atomic_t" \
7938                 "int"
7939         do
7940         AC_TRY_COMPILE([
7941 #include <sys/types.h>
7942 #include <signal.h>
7943 #include <stdio.h>
7944
7945 extern $cf_type x;
7946 $cf_type x;
7947 static void handler(int sig)
7948 {
7949         (void)sig;
7950         x = 5;
7951 }],
7952                 [signal(SIGINT, handler);
7953                  x = 1],
7954                 [cf_cv_sig_atomic_t=$cf_type],
7955                 [cf_cv_sig_atomic_t=no])
7956                 test "$cf_cv_sig_atomic_t" != no && break
7957         done
7958         ])
7959 AC_MSG_RESULT($cf_cv_sig_atomic_t)
7960 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
7961 ])dnl
7962 dnl ---------------------------------------------------------------------------
7963 dnl CF_SIZECHANGE version: 18 updated: 2021/09/04 06:35:04
7964 dnl -------------
7965 dnl Check for definitions & structures needed for window size-changing
7966 dnl
7967 dnl https://stackoverflow.com/questions/18878141/difference-between-structures-ttysize-and-winsize/50769952#50769952
7968 AC_DEFUN([CF_SIZECHANGE],
7969 [
7970 AC_REQUIRE([CF_STRUCT_TERMIOS])
7971 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
7972         cf_cv_sizechange=unknown
7973         cf_save_CPPFLAGS="$CPPFLAGS"
7974
7975 for cf_opts in "" "NEED_PTEM_H"
7976 do
7977
7978         CPPFLAGS="$cf_save_CPPFLAGS"
7979         if test -n "$cf_opts"
7980         then
7981                 CF_APPEND_TEXT(CPPFLAGS,-D$cf_opts)
7982         fi
7983         AC_TRY_COMPILE([#include <sys/types.h>
7984 #ifdef HAVE_TERMIOS_H
7985 #include <termios.h>
7986 #else
7987 #ifdef HAVE_TERMIO_H
7988 #include <termio.h>
7989 #endif
7990 #endif
7991
7992 #ifdef NEED_PTEM_H
7993 /* This is a workaround for SCO:  they neglected to define struct winsize in
7994  * termios.h -- it is only in termio.h and ptem.h
7995  */
7996 #include <sys/stream.h>
7997 #include <sys/ptem.h>
7998 #endif
7999
8000 #ifdef HAVE_SYS_IOCTL_H
8001 #include <sys/ioctl.h>
8002 #endif
8003 ],[
8004 #ifdef TIOCGSIZE
8005         struct ttysize win;     /* SunOS 3.0... */
8006         int y = win.ts_lines = 2;
8007         int x = win.ts_cols = 1;
8008         (void)y;
8009         (void)x;
8010 #else
8011 #ifdef TIOCGWINSZ
8012         struct winsize win;     /* everything else */
8013         int y = win.ws_row = 2;
8014         int x = win.ws_col = 1;
8015         (void)y;
8016         (void)x;
8017 #else
8018         no TIOCGSIZE or TIOCGWINSZ
8019 #endif /* TIOCGWINSZ */
8020 #endif /* TIOCGSIZE */
8021         ],
8022         [cf_cv_sizechange=yes],
8023         [cf_cv_sizechange=no])
8024
8025         CPPFLAGS="$cf_save_CPPFLAGS"
8026         if test "$cf_cv_sizechange" = yes ; then
8027                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
8028                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
8029                 break
8030         fi
8031 done
8032 ])
8033 if test "$cf_cv_sizechange" != no ; then
8034         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechange declarations are provided])
8035         case "$cf_cv_sizechange" in
8036         (NEED*)
8037                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
8038                 ;;
8039         esac
8040 fi
8041 ])dnl
8042 dnl ---------------------------------------------------------------------------
8043 dnl CF_SRC_MODULES version: 33 updated: 2021/01/01 13:31:04
8044 dnl --------------
8045 dnl For each parameter, test if the source-directory exists, and if it contains
8046 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
8047 dnl use in CF_LIB_RULES.
8048 dnl
8049 dnl This uses the configured value to make the lists SRC_SUBDIRS and
8050 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
8051 AC_DEFUN([CF_SRC_MODULES],
8052 [
8053 AC_REQUIRE([CF_CHECK_GNAT_VERSION])
8054 AC_MSG_CHECKING(for src modules)
8055
8056 # dependencies and linker-arguments for test-programs
8057 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
8058 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
8059 if test "$DFT_LWR_MODEL" = "libtool"; then
8060         TEST_ARGS="${TEST_DEPS}"
8061         TEST_ARG2="${TEST_DEP2}"
8062 else
8063         TEST_ARGS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
8064         TEST_ARG2="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARG2"
8065 fi
8066
8067 PC_MODULES_TO_MAKE="ncurses${USE_ARG_SUFFIX}"
8068 cf_cv_src_modules=
8069 for cf_dir in $1
8070 do
8071         if test -f "$srcdir/$cf_dir/modules" ; then
8072
8073                 # We may/may not have tack in the distribution, though the
8074                 # makefile is.
8075                 if test "$cf_dir" = tack ; then
8076                         if test "x$cf_with_tack" != "xyes"; then
8077                                 continue
8078                         fi
8079                 fi
8080
8081                 if test -z "$cf_cv_src_modules"; then
8082                         cf_cv_src_modules=$cf_dir
8083                 else
8084                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
8085                 fi
8086
8087                 # Make the ncurses_cfg.h file record the library interface files as
8088                 # well.  These are header files that are the same name as their
8089                 # directory.  Ncurses is the only library that does not follow
8090                 # that pattern.
8091                 if test "$cf_dir" = tack ; then
8092                         continue
8093                 elif test -f "$srcdir/${cf_dir}/${cf_dir}.h" ; then
8094                         CF_UPPER(cf_have_include,$cf_dir)
8095                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
8096                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
8097                         CF_MAP_LIB_BASENAME(TEST_ROOT,$cf_dir)
8098                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEPS"
8099                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEP2"
8100                         if test "$DFT_LWR_MODEL" = "libtool"; then
8101                                 TEST_ARGS="${TEST_DEPS}"
8102                                 TEST_ARG2="${TEST_DEP2}"
8103                         else
8104                                 TEST_ARGS="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARGS"
8105                                 TEST_ARG2="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARG2"
8106                         fi
8107                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${USE_ARG_SUFFIX}"
8108                 fi
8109         fi
8110 done
8111 AC_MSG_RESULT($cf_cv_src_modules)
8112
8113 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
8114 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
8115
8116 AC_SUBST(TEST_ARGS)
8117 AC_SUBST(TEST_DEPS)
8118
8119 AC_SUBST(TEST_ARG2)
8120 AC_SUBST(TEST_DEP2)
8121
8122 SRC_SUBDIRS=
8123 if test "x$cf_with_manpages" != xno ; then
8124         SRC_SUBDIRS="$SRC_SUBDIRS man"
8125 fi
8126 SRC_SUBDIRS="$SRC_SUBDIRS include"
8127 for cf_dir in $cf_cv_src_modules
8128 do
8129         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
8130 done
8131 if test "x$cf_with_tests" != "xno" ; then
8132         SRC_SUBDIRS="$SRC_SUBDIRS test"
8133 fi
8134 # always make this, to install the ncurses-config script
8135 SRC_SUBDIRS="$SRC_SUBDIRS misc"
8136 if test "$cf_with_cxx_binding" != no; then
8137         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${USE_ARG_SUFFIX}"
8138         SRC_SUBDIRS="$SRC_SUBDIRS c++"
8139 fi
8140
8141 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
8142 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
8143
8144 AC_SUBST(PC_MODULES_TO_MAKE)
8145
8146 ADA_SUBDIRS=
8147 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f "$srcdir/Ada95/Makefile.in" ; then
8148         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
8149         ADA_SUBDIRS="gen src"
8150         if test "x$cf_with_tests" != "xno" ; then
8151                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
8152         fi
8153 fi
8154
8155 SUB_MAKEFILES=
8156 for cf_dir in $SRC_SUBDIRS
8157 do
8158         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
8159 done
8160
8161 if test -n "$ADA_SUBDIRS"; then
8162         for cf_dir in $ADA_SUBDIRS
8163         do
8164                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
8165         done
8166         AC_SUBST(ADA_SUBDIRS)
8167 fi
8168 ])dnl
8169 dnl ---------------------------------------------------------------------------
8170 dnl CF_STDCPP_LIBRARY version: 12 updated: 2021/01/01 13:31:04
8171 dnl -----------------
8172 dnl Check for -lstdc++, which is GNU's standard C++ library.
8173 dnl If $CXXLIBS is set, add that to the libraries used for test-linking.
8174 dnl If -lstdc++ was not already added to $LIBS or $CXXLIBS, and is needed,
8175 dnl add it to $CXXLIBS.
8176 AC_DEFUN([CF_STDCPP_LIBRARY],
8177 [
8178 if test -n "$GXX" ; then
8179
8180         cf_save="$LIBS"
8181         LIBS="$LIBS $CXXLIBS"
8182         AC_MSG_CHECKING(if we already have C++ library)
8183         AC_TRY_LINK([
8184                         #include <iostream>],[
8185                         std::cout << "Hello World!" << std::endl;],
8186                 [cf_have_libstdcpp=yes],
8187                 [cf_have_libstdcpp=no])
8188         AC_MSG_RESULT($cf_have_libstdcpp)
8189         LIBS="$cf_save"
8190
8191         if test "$cf_have_libstdcpp" != yes
8192         then
8193                 case "$cf_cv_system_name" in
8194                 (os2*)
8195                         if test -z "`g++ -dM -E - < /dev/null | grep __KLIBC__`"; then
8196                                 cf_stdcpp_libname=stdcpp
8197                         else
8198                                 cf_stdcpp_libname=stdc++
8199                         fi
8200                         ;;
8201                 (*)
8202                         cf_stdcpp_libname=stdc++
8203                         ;;
8204                 esac
8205
8206                 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
8207                         cf_save="$LIBS"
8208                         LIBS="$LIBS $CXXLIBS"
8209                         CF_ADD_LIB($cf_stdcpp_libname)
8210                 AC_TRY_LINK([
8211                                 #include <iostream>],[
8212                                 std::cout << "Hello World!" << std::endl;],
8213                         [cf_cv_libstdcpp=yes],
8214                         [cf_cv_libstdcpp=no])
8215                         LIBS="$cf_save"
8216                 ])
8217                 test "$cf_cv_libstdcpp" = yes && { CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS) }
8218         fi
8219 fi
8220 ])dnl
8221 dnl ---------------------------------------------------------------------------
8222 dnl CF_STRIP_G_OPT version: 4 updated: 2021/01/02 09:31:20
8223 dnl --------------
8224 dnl     Remove "-g" option from the compiler options
8225 AC_DEFUN([CF_STRIP_G_OPT],
8226 [$1=`echo "${$1}" | CF__SED_TRIMBLANKS(-e 's%-g %%' -e 's%-g$%%')`])dnl
8227 dnl ---------------------------------------------------------------------------
8228 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
8229 dnl -------------------
8230 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
8231 dnl do this if we've found the sigaction function.
8232 AC_DEFUN([CF_STRUCT_SIGACTION],[
8233 AC_REQUIRE([CF_XOPEN_SOURCE])
8234
8235 if test "$ac_cv_func_sigaction" = yes; then
8236 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
8237 AC_TRY_COMPILE([
8238 #include <sys/types.h>
8239 #include <signal.h>],
8240         [struct sigaction act],
8241         [sigact_bad=no],
8242         [
8243 AC_TRY_COMPILE([
8244 #define _POSIX_SOURCE
8245 #include <sys/types.h>
8246 #include <signal.h>],
8247         [struct sigaction act],
8248         [sigact_bad=yes
8249          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
8250          [sigact_bad=unknown])])
8251 AC_MSG_RESULT($sigact_bad)
8252 fi
8253 ])dnl
8254 dnl ---------------------------------------------------------------------------
8255 dnl CF_STRUCT_TERMIOS version: 11 updated: 2020/03/19 20:46:13
8256 dnl -----------------
8257 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
8258 AC_DEFUN([CF_STRUCT_TERMIOS],[
8259 AC_REQUIRE([CF_XOPEN_SOURCE])
8260
8261 AC_CHECK_HEADERS( \
8262 termio.h \
8263 termios.h \
8264 unistd.h \
8265 sys/ioctl.h \
8266 sys/termio.h \
8267 )
8268
8269 if test "$ac_cv_header_termios_h" = yes ; then
8270         case "$CFLAGS $CPPFLAGS" in
8271         (*-D_POSIX_SOURCE*)
8272                 termios_bad=dunno ;;
8273         (*)     termios_bad=maybe ;;
8274         esac
8275         if test "$termios_bad" = maybe ; then
8276         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
8277         AC_TRY_COMPILE([#include <termios.h>],
8278                 [struct termios foo; int x = foo.c_iflag = 1; (void)x],
8279                 termios_bad=no, [
8280                 AC_TRY_COMPILE([
8281 #define _POSIX_SOURCE
8282 #include <termios.h>],
8283                         [struct termios foo; int x = foo.c_iflag = 2; (void)x],
8284                         termios_bad=unknown,
8285                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
8286                         ])
8287         AC_MSG_RESULT($termios_bad)
8288         fi
8289 fi
8290 ])dnl
8291 dnl ---------------------------------------------------------------------------
8292 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
8293 dnl --------------
8294 dnl Construct a search-list for a nonstandard header/lib-file
8295 dnl     $1 = the variable to return as result
8296 dnl     $2 = the package name
8297 dnl     $3 = the subdirectory, e.g., bin, include or lib
8298 AC_DEFUN([CF_SUBDIR_PATH],
8299 [
8300 $1=
8301
8302 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
8303
8304 for cf_subdir_prefix in \
8305         /usr \
8306         /usr/local \
8307         /usr/pkg \
8308         /opt \
8309         /opt/local \
8310         [$]HOME
8311 do
8312         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
8313 done
8314 ])dnl
8315 dnl ---------------------------------------------------------------------------
8316 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
8317 dnl -----------
8318 dnl     Shorthand macro for substituting things that the user may override
8319 dnl     with an environment variable.
8320 dnl
8321 dnl     $1 = condition to pass to "test"
8322 dnl     $2 = environment variable
8323 dnl     $3 = value if the test succeeds
8324 dnl     $4 = value if the test fails
8325 AC_DEFUN([CF_SUBST_IF],
8326 [
8327 if test $1 ; then
8328         $2=$3
8329 ifelse($4,,,[else
8330         $2=$4])
8331 fi
8332 AC_SUBST($2)
8333 ])dnl
8334 dnl ---------------------------------------------------------------------------
8335 dnl CF_SUBST_NCURSES_VERSION version: 10 updated: 2021/01/04 18:48:01
8336 dnl ------------------------
8337 dnl Get the version-number for use in shared-library naming, etc.
8338 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
8339 [AC_REQUIRE([AC_PROG_EGREP])dnl
8340
8341 NCURSES_MAJOR="`${EGREP-egrep} '^NCURSES_MAJOR[[        ]]*=' "$srcdir/dist.mk" | sed -e 's/^[[^0-9]]*//'`"
8342 NCURSES_MINOR="`${EGREP-egrep} '^NCURSES_MINOR[[        ]]*=' "$srcdir/dist.mk" | sed -e 's/^[[^0-9]]*//'`"
8343 NCURSES_PATCH="`${EGREP-egrep} '^NCURSES_PATCH[[        ]]*=' "$srcdir/dist.mk" | sed -e 's/^[[^0-9]]*//'`"
8344 cf_cv_abi_version=${NCURSES_MAJOR}
8345 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
8346 dnl Show the computed version, for logging
8347 cf_cv_timestamp=`date`
8348 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
8349 dnl We need these values in the generated headers
8350 AC_SUBST(NCURSES_MAJOR)
8351 AC_SUBST(NCURSES_MINOR)
8352 AC_SUBST(NCURSES_PATCH)
8353 dnl We need these values in the generated makefiles
8354 AC_SUBST(cf_cv_rel_version)
8355 AC_SUBST(cf_cv_abi_version)
8356 AC_SUBST(cf_cv_builtin_bool)
8357 AC_SUBST(cf_cv_header_stdbool_h)
8358 AC_SUBST(cf_cv_type_of_bool)dnl
8359 ])dnl
8360 dnl ---------------------------------------------------------------------------
8361 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
8362 dnl ------------------
8363 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
8364 dnl older SCO configurations.
8365 AC_DEFUN([CF_SYS_TIME_SELECT],
8366 [
8367 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
8368 AC_CACHE_VAL(cf_cv_sys_time_select,[
8369 AC_TRY_COMPILE([
8370 #include <sys/types.h>
8371 #ifdef HAVE_SYS_TIME_H
8372 #include <sys/time.h>
8373 #endif
8374 #ifdef HAVE_SYS_SELECT_H
8375 #include <sys/select.h>
8376 #endif
8377 ],[],[cf_cv_sys_time_select=yes],
8378          [cf_cv_sys_time_select=no])
8379          ])
8380 AC_MSG_RESULT($cf_cv_sys_time_select)
8381 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
8382 ])dnl
8383 dnl ---------------------------------------------------------------------------
8384 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
8385 dnl ---------------
8386 dnl Define a top_builddir symbol, for applications that need an absolute path.
8387 AC_DEFUN([CF_TOP_BUILDDIR],
8388 [
8389 top_builddir=ifelse($1,,`pwd`,$1)
8390 AC_SUBST(top_builddir)
8391 ])dnl
8392 dnl ---------------------------------------------------------------------------
8393 dnl CF_TRY_PKG_CONFIG version: 6 updated: 2020/12/31 10:54:15
8394 dnl -----------------
8395 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
8396 dnl available in that form.
8397 dnl
8398 dnl $1 = package name, which may be a shell variable
8399 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
8400 dnl $3 = logic to use if pkg-config does not have the package
8401 AC_DEFUN([CF_TRY_PKG_CONFIG],[
8402 AC_REQUIRE([CF_PKG_CONFIG])
8403
8404 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists "$1"; then
8405         CF_VERBOSE(found package $1)
8406         cf_pkgconfig_incs="`$PKG_CONFIG --cflags "$1" 2>/dev/null`"
8407         cf_pkgconfig_libs="`$PKG_CONFIG --libs   "$1" 2>/dev/null`"
8408         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
8409         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
8410         CF_ADD_CFLAGS($cf_pkgconfig_incs)
8411         CF_ADD_LIBS($cf_pkgconfig_libs)
8412         ifelse([$2],,:,[$2])
8413 else
8414         cf_pkgconfig_incs=
8415         cf_pkgconfig_libs=
8416         ifelse([$3],,:,[$3])
8417 fi
8418 ])
8419 dnl ---------------------------------------------------------------------------
8420 dnl CF_TRY_XOPEN_SOURCE version: 4 updated: 2022/09/10 15:16:16
8421 dnl -------------------
8422 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
8423 dnl can define it successfully.
8424 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
8425 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
8426         AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,
8427         [cf_cv_xopen_source=no],
8428         [cf_save="$CPPFLAGS"
8429          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
8430          AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,
8431                 [cf_cv_xopen_source=no],
8432                 [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
8433                 CPPFLAGS="$cf_save"
8434         ])
8435 ])
8436
8437 if test "$cf_cv_xopen_source" != no ; then
8438         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
8439         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
8440         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
8441         CF_APPEND_CFLAGS($cf_temp_xopen_source)
8442 fi
8443 ])
8444 dnl ---------------------------------------------------------------------------
8445 dnl CF_TYPEOF_CHTYPE version: 10 updated: 2017/01/21 11:06:25
8446 dnl ----------------
8447 dnl Determine the type we should use for chtype (and attr_t, which is treated
8448 dnl as the same thing).  We want around 32 bits, so on most machines want a
8449 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
8450 dnl wide characters, we have to have a type compatible with that, as well.
8451 AC_DEFUN([CF_TYPEOF_CHTYPE],
8452 [
8453 AC_MSG_CHECKING([for type of chtype])
8454 AC_CACHE_VAL(cf_cv_typeof_chtype,[
8455                 AC_TRY_RUN([
8456 #define WANT_BITS 31
8457 #include <stdio.h>
8458 int main(void)
8459 {
8460         FILE *fp = fopen("cf_test.out", "w");
8461         if (fp != 0) {
8462                 char *result = "long";
8463                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
8464                         int n;
8465                         unsigned int x, y;
8466                         for (n = 0; n < WANT_BITS; n++) {
8467                                 x = (1 << n);
8468                                 y = (x >> n);
8469                                 if (y != 1 || x == 0) {
8470                                         x = 0;
8471                                         break;
8472                                 }
8473                         }
8474                         /*
8475                          * If x is nonzero, an int is big enough for the bits
8476                          * that we want.
8477                          */
8478                         result = (x != 0) ? "int" : "long";
8479                 }
8480                 fputs(result, fp);
8481                 fclose(fp);
8482         }
8483         ${cf_cv_main_return:-return}(0);
8484 }
8485                 ],
8486                 [cf_cv_typeof_chtype=`cat cf_test.out`],
8487                 [cf_cv_typeof_chtype=long],
8488                 [cf_cv_typeof_chtype=long])
8489                 rm -f cf_test.out
8490         ])
8491 AC_MSG_RESULT($cf_cv_typeof_chtype)
8492
8493 AC_SUBST(cf_cv_typeof_chtype)
8494 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
8495 ])dnl
8496 dnl ---------------------------------------------------------------------------
8497 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
8498 dnl -----------------
8499 dnl
8500 AC_DEFUN([CF_TYPE_SIGACTION],
8501 [
8502 AC_MSG_CHECKING([for type sigaction_t])
8503 AC_CACHE_VAL(cf_cv_type_sigaction,[
8504         AC_TRY_COMPILE([
8505 #include <signal.h>],
8506                 [sigaction_t x],
8507                 [cf_cv_type_sigaction=yes],
8508                 [cf_cv_type_sigaction=no])])
8509 AC_MSG_RESULT($cf_cv_type_sigaction)
8510 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
8511 ])dnl
8512 dnl ---------------------------------------------------------------------------
8513 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
8514 dnl --------------------
8515 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
8516 dnl won't, but they're still there.
8517 AC_DEFUN([CF_UNSIGNED_LITERALS],
8518 [
8519 AC_MSG_CHECKING([if unsigned literals are legal])
8520 AC_CACHE_VAL(cf_cv_unsigned_literals,[
8521         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
8522                 [cf_cv_unsigned_literals=yes],
8523                 [cf_cv_unsigned_literals=no])
8524         ])
8525 AC_MSG_RESULT($cf_cv_unsigned_literals)
8526 ])dnl
8527 dnl ---------------------------------------------------------------------------
8528 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
8529 dnl --------
8530 dnl Make an uppercase version of a variable
8531 dnl $1=uppercase($2)
8532 AC_DEFUN([CF_UPPER],
8533 [
8534 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
8535 ])dnl
8536 dnl ---------------------------------------------------------------------------
8537 dnl CF_UTF8_LIB version: 9 updated: 2021/05/19 19:35:25
8538 dnl -----------
8539 dnl Check for multibyte support, and if not found, utf8 compatibility library
8540 AC_DEFUN([CF_UTF8_LIB],
8541 [
8542 AC_HAVE_HEADERS(wchar.h)
8543 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
8544         cf_save_LIBS="$LIBS"
8545         AC_TRY_LINK([
8546 #include <stdlib.h>
8547 #include <stdio.h>
8548 #ifdef HAVE_WCHAR_H
8549 #include <wchar.h>
8550 #endif
8551 ],[putwc(0,0);],
8552         [cf_cv_utf8_lib=yes],
8553         [CF_FIND_LINKAGE([
8554 #include <libutf8.h>],[putwc(0,0);],utf8,
8555                 [cf_cv_utf8_lib=add-on],
8556                 [cf_cv_utf8_lib=no])
8557 ])])
8558
8559 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
8560 # ncurses/ncursesw:
8561 if test "$cf_cv_utf8_lib" = "add-on" ; then
8562         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
8563         CF_ADD_INCDIR($cf_cv_header_path_utf8)
8564         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
8565         CF_ADD_LIBS($cf_cv_library_file_utf8)
8566 fi
8567 ])dnl
8568 dnl ---------------------------------------------------------------------------
8569 dnl CF_VA_COPY version: 6 updated: 2018/12/04 18:14:25
8570 dnl ----------
8571 dnl check for va_copy, part of stdarg.h starting with ISO C 1999.
8572 dnl Also, workaround for glibc's __va_copy, by checking for both.
8573 dnl Finally, try to accommodate pre-ISO C 1999 headers.
8574 AC_DEFUN([CF_VA_COPY],[
8575 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
8576 AC_TRY_LINK([
8577 #include <stdarg.h>
8578 ],[
8579         static va_list dst;
8580         static va_list src;
8581         va_copy(dst, src)],
8582         cf_cv_have_va_copy=yes,
8583         cf_cv_have_va_copy=no)])
8584
8585 if test "$cf_cv_have_va_copy" = yes;
8586 then
8587         AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
8588 else # !cf_cv_have_va_copy
8589
8590 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
8591 AC_TRY_LINK([
8592 #include <stdarg.h>
8593 ],[
8594         static va_list dst;
8595         static va_list src;
8596         __va_copy(dst, src)],
8597         cf_cv_have___va_copy=yes,
8598         cf_cv_have___va_copy=no)])
8599
8600 if test "$cf_cv_have___va_copy" = yes
8601 then
8602         AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
8603 else # !cf_cv_have___va_copy
8604
8605 AC_CACHE_CHECK(for __builtin_va_copy, cf_cv_have___builtin_va_copy,[
8606 AC_TRY_LINK([
8607 #include <stdarg.h>
8608 ],[
8609         static va_list dst;
8610         static va_list src;
8611         __builtin_va_copy(dst, src)],
8612         cf_cv_have___builtin_va_copy=yes,
8613         cf_cv_have___builtin_va_copy=no)])
8614
8615 test "$cf_cv_have___builtin_va_copy" = yes &&
8616         AC_DEFINE(HAVE___BUILTIN_VA_COPY,1,[Define to 1 if we have __builtin_va_copy])
8617
8618 fi # cf_cv_have___va_copy
8619
8620 fi # cf_cv_have_va_copy
8621
8622 case "${cf_cv_have_va_copy}${cf_cv_have___va_copy}${cf_cv_have___builtin_va_copy}" in
8623 (*yes*)
8624         ;;
8625
8626 (*)
8627         AC_CACHE_CHECK(if we can simply copy va_list, cf_cv_pointer_va_list,[
8628 AC_TRY_LINK([
8629 #include <stdarg.h>
8630 ],[
8631         va_list dst;
8632         va_list src;
8633         dst = src],
8634         cf_cv_pointer_va_list=yes,
8635         cf_cv_pointer_va_list=no)])
8636
8637         if test "$cf_cv_pointer_va_list" = no
8638         then
8639                 AC_CACHE_CHECK(if we can copy va_list indirectly, cf_cv_array_va_list,[
8640 AC_TRY_LINK([
8641 #include <stdarg.h>
8642 ],[
8643         va_list dst;
8644         va_list src;
8645         *dst = *src],
8646                         cf_cv_array_va_list=yes,
8647                         cf_cv_array_va_list=no)])
8648                 test "$cf_cv_array_va_list" = yes && AC_DEFINE(ARRAY_VA_LIST,1,[Define to 1 if we can copy va_list indirectly])
8649         fi
8650         ;;
8651 esac
8652 ])
8653 dnl ---------------------------------------------------------------------------
8654 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
8655 dnl ----------
8656 dnl Use AC_VERBOSE w/o the warnings
8657 AC_DEFUN([CF_VERBOSE],
8658 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
8659 CF_MSG_LOG([$1])
8660 ])dnl
8661 dnl ---------------------------------------------------------------------------
8662 dnl CF_VERSION_INFO version: 8 updated: 2021/01/01 13:31:04
8663 dnl ---------------
8664 dnl Define several useful symbols derived from the VERSION file.  A separate
8665 dnl file is preferred to embedding the version numbers in various scripts.
8666 dnl (automake is a textbook-example of why the latter is a bad idea, but there
8667 dnl are others).
8668 dnl
8669 dnl The file contents are:
8670 dnl     libtool-version release-version patch-version
8671 dnl or
8672 dnl     release-version
8673 dnl where
8674 dnl     libtool-version (see ?) consists of 3 integers separated by '.'
8675 dnl     release-version consists of a major version and minor version
8676 dnl             separated by '.', optionally followed by a patch-version
8677 dnl             separated by '-'.  The minor version need not be an
8678 dnl             integer (but it is preferred).
8679 dnl     patch-version is an integer in the form yyyymmdd, so ifdef's and
8680 dnl             scripts can easily compare versions.
8681 dnl
8682 dnl If libtool is used, the first form is required, since CF_WITH_LIBTOOL
8683 dnl simply extracts the first field using 'cut -f1'.
8684 dnl
8685 dnl Optional parameters:
8686 dnl $1 = internal name for package
8687 dnl $2 = external name for package
8688 AC_DEFUN([CF_VERSION_INFO],
8689 [
8690 if test -f "$srcdir/VERSION" ; then
8691         AC_MSG_CHECKING(for package version)
8692
8693         # if there are not enough fields, cut returns the last one...
8694         cf_field1=`sed -e '2,$d' "$srcdir/VERSION" |cut -f1`
8695         cf_field2=`sed -e '2,$d' "$srcdir/VERSION" |cut -f2`
8696         cf_field3=`sed -e '2,$d' "$srcdir/VERSION" |cut -f3`
8697
8698         # this is how CF_BUNDLED_INTL uses $VERSION:
8699         VERSION="$cf_field1"
8700
8701         VERSION_MAJOR=`echo "$cf_field2" | sed -e 's/\..*//'`
8702         test -z "$VERSION_MAJOR" && AC_MSG_ERROR(missing major-version)
8703
8704         VERSION_MINOR=`echo "$cf_field2" | sed -e 's/^[[^.]]*\.//' -e 's/-.*//'`
8705         test -z "$VERSION_MINOR" && AC_MSG_ERROR(missing minor-version)
8706
8707         AC_MSG_RESULT(${VERSION_MAJOR}.${VERSION_MINOR})
8708
8709         AC_MSG_CHECKING(for package patch date)
8710         VERSION_PATCH=`echo "$cf_field3" | sed -e 's/^[[^-]]*-//'`
8711         case .$VERSION_PATCH in
8712         (.)
8713                 AC_MSG_ERROR(missing patch-date $VERSION_PATCH)
8714                 ;;
8715         (.[[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]])
8716                 ;;
8717         (*)
8718                 AC_MSG_ERROR(illegal patch-date $VERSION_PATCH)
8719                 ;;
8720         esac
8721         AC_MSG_RESULT($VERSION_PATCH)
8722 else
8723         AC_MSG_ERROR(did not find $srcdir/VERSION)
8724 fi
8725
8726 # show the actual data that we have for versions:
8727 CF_VERBOSE(ABI VERSION $VERSION)
8728 CF_VERBOSE(VERSION_MAJOR $VERSION_MAJOR)
8729 CF_VERBOSE(VERSION_MINOR $VERSION_MINOR)
8730 CF_VERBOSE(VERSION_PATCH $VERSION_PATCH)
8731
8732 AC_SUBST(VERSION)
8733 AC_SUBST(VERSION_MAJOR)
8734 AC_SUBST(VERSION_MINOR)
8735 AC_SUBST(VERSION_PATCH)
8736
8737 dnl if a package name is given, define its corresponding version info.  We
8738 dnl need the package name to ensure that the defined symbols are unique.
8739 ifelse($1,,,[
8740         cf_PACKAGE=$1
8741         PACKAGE=ifelse($2,,$1,$2)
8742         AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",[Define to the package-name])
8743         AC_SUBST(PACKAGE)
8744         CF_UPPER(cf_PACKAGE,$cf_PACKAGE)
8745         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_VERSION,"${VERSION_MAJOR}.${VERSION_MINOR}")
8746         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_PATCHDATE,${VERSION_PATCH})
8747 ])
8748 ])dnl
8749 dnl ---------------------------------------------------------------------------
8750 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
8751 dnl -------------
8752 dnl Check if type wide-character type $1 is declared, and if so, which header
8753 dnl file is needed.  The second parameter is used to set a shell variable when
8754 dnl the type is not found.  The first parameter sets a shell variable for the
8755 dnl opposite sense.
8756 AC_DEFUN([CF_WCHAR_TYPE],
8757 [
8758 # This is needed on Tru64 5.0 to declare $1
8759 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
8760 AC_TRY_COMPILE([
8761 #include <stdlib.h>
8762 #include <stdarg.h>
8763 #include <stdio.h>
8764 #ifdef HAVE_LIBUTF8_H
8765 #include <libutf8.h>
8766 #endif],
8767         [$1 state],
8768         [cf_cv_$1=no],
8769         [AC_TRY_COMPILE([
8770 #include <stdlib.h>
8771 #include <stdarg.h>
8772 #include <stdio.h>
8773 #include <wchar.h>
8774 #ifdef HAVE_LIBUTF8_H
8775 #include <libutf8.h>
8776 #endif],
8777         [$1 value],
8778         [cf_cv_$1=yes],
8779         [cf_cv_$1=unknown])])])
8780
8781 if test "$cf_cv_$1" = yes ; then
8782         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
8783         NEED_WCHAR_H=1
8784 fi
8785
8786 ifelse([$2],,,[
8787 # if we do not find $1 in either place, use substitution to provide a fallback.
8788 if test "$cf_cv_$1" = unknown ; then
8789         $2=1
8790 fi
8791 ])
8792 ifelse($3,,,[
8793 # if we find $1 in either place, use substitution to provide a fallback.
8794 if test "$cf_cv_$1" != unknown ; then
8795         $3=1
8796 fi
8797 ])
8798 ])dnl
8799 dnl ---------------------------------------------------------------------------
8800 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
8801 dnl ---------------
8802 dnl Check for compiler-support for weak symbols.
8803 dnl This works with "recent" gcc.
8804 AC_DEFUN([CF_WEAK_SYMBOLS],[
8805 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
8806
8807 AC_TRY_COMPILE([
8808 #include <stdio.h>],
8809 [
8810 #if defined(__GNUC__)
8811 #  if defined __USE_ISOC99
8812 #    define _cat_pragma(exp)    _Pragma(#exp)
8813 #    define _weak_pragma(exp)   _cat_pragma(weak name)
8814 #  else
8815 #    define _weak_pragma(exp)
8816 #  endif
8817 #  define _declare(name)        __extension__ extern __typeof__(name) name
8818 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
8819 #endif
8820
8821 weak_symbol(fopen);
8822 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
8823 ])
8824 ])dnl
8825 dnl ---------------------------------------------------------------------------
8826 dnl CF_WITH_ABI_VERSION version: 4 updated: 2021/01/01 13:31:04
8827 dnl -------------------
8828 dnl Allow library's ABI to be overridden.  Generally this happens when a
8829 dnl packager has incremented the ABI past that used in the original package,
8830 dnl and wishes to keep doing this.
8831 dnl
8832 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
8833 dnl symbol.
8834 AC_DEFUN([CF_WITH_ABI_VERSION],[
8835 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
8836 AC_ARG_WITH(abi-version,
8837 [  --with-abi-version=XXX  override derived ABI version],[
8838         if test "x$cf_cv_abi_version" != "x$withval"
8839         then
8840                 AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
8841                 case "$cf_cv_rel_version" in
8842                 (5.*)
8843                         cf_cv_rel_version=$withval.0
8844                         ;;
8845                 (6.*)
8846                         cf_cv_rel_version=$withval.9    # FIXME: should be 10 as of 6.0 release
8847                         ;;
8848                 esac
8849         fi
8850         cf_cv_abi_version=$withval])
8851         CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
8852 ifelse($1,,,[
8853 $1_ABI=$cf_cv_abi_version
8854 ])
8855 ])dnl
8856 dnl ---------------------------------------------------------------------------
8857 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
8858 dnl --------------------
8859 dnl Command-line option to specify the Ada95 compiler.
8860 AC_DEFUN([CF_WITH_ADA_COMPILER],[
8861 AC_MSG_CHECKING(for ada-compiler)
8862 AC_ARG_WITH(ada-compiler,
8863         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
8864         [cf_ada_compiler=$withval],
8865         [cf_ada_compiler=gnatmake])
8866 AC_SUBST(cf_ada_compiler)
8867 AC_MSG_RESULT($cf_ada_compiler)
8868 ])dnl
8869 dnl ---------------------------------------------------------------------------
8870 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
8871 dnl -------------------
8872 dnl Command-line option to specify where Ada includes will install.
8873 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
8874 AC_MSG_CHECKING(for ada-include)
8875 CF_WITH_PATH(ada-include,
8876    [  --with-ada-include=DIR  Ada includes are in DIR],
8877    ADA_INCLUDE,
8878    PREFIX/share/ada/adainclude,
8879    [$]prefix/share/ada/adainclude)
8880 AC_SUBST(ADA_INCLUDE)
8881 AC_MSG_RESULT($ADA_INCLUDE)
8882 ])dnl
8883 dnl ---------------------------------------------------------------------------
8884 dnl CF_WITH_ADA_LIBNAME version: 1 updated: 2019/09/07 18:59:41
8885 dnl -------------------
8886 dnl CF_WITH_ADA_LIBNAME
8887 dnl -------------------
8888 dnl Command-line option to specify how to name the resulting Ada library.
8889 dnl $1 = default value
8890 AC_DEFUN([CF_WITH_ADA_LIBNAME],[
8891 AC_MSG_CHECKING(for ada-libname)
8892 AC_ARG_WITH(ada-libname,
8893    [  --with-ada-libname=XXX  override default Ada library-name],
8894    ADA_LIBNAME=[$]withval,
8895    ADA_LIBNAME=$1)
8896 case "x$ADA_LIBNAME" in
8897 (x|xyes|xno)
8898         ADA_LIBNAME=$1
8899         ;;
8900 esac
8901 AC_SUBST(ADA_LIBNAME)
8902 AC_MSG_RESULT($ADA_LIBNAME)
8903 ])dnl
8904 dnl ---------------------------------------------------------------------------
8905 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
8906 dnl -------------------
8907 dnl Command-line option to specify where Ada objects will install.
8908 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
8909 AC_MSG_CHECKING(for ada-objects)
8910 CF_WITH_PATH(ada-objects,
8911    [  --with-ada-objects=DIR  Ada objects are in DIR],
8912    ADA_OBJECTS,
8913    PREFIX/lib/ada/adalib,
8914    [$]prefix/lib/ada/adalib)
8915 AC_SUBST(ADA_OBJECTS)
8916 AC_MSG_RESULT($ADA_OBJECTS)
8917 ])dnl
8918 dnl ---------------------------------------------------------------------------
8919 dnl CF_WITH_ADA_SHAREDLIB version: 5 updated: 2018/07/21 19:10:35
8920 dnl ---------------------
8921 dnl Command-line option to specify if an Ada95 shared-library should be built,
8922 dnl and optionally what its soname should be.
8923 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
8924 AC_REQUIRE([CF_GNAT_PROJECTS])
8925 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
8926 AC_ARG_WITH(ada-sharedlib,
8927         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
8928         [with_ada_sharedlib=$withval],
8929         [with_ada_sharedlib=no])
8930 AC_MSG_RESULT($with_ada_sharedlib)
8931
8932 if test "x$with_ada_sharedlib" != xno
8933 then
8934         if test "x$cf_gnat_projects" != xyes
8935         then
8936                 AC_MSG_WARN(disabling shared-library since GNAT projects are not supported)
8937                 with_ada_sharedlib=no
8938         fi
8939 fi
8940
8941 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
8942 MAKE_ADA_SHAREDLIB="#"
8943
8944 if test "x$with_ada_sharedlib" != xno
8945 then
8946         MAKE_ADA_SHAREDLIB=
8947         if test "x$with_ada_sharedlib" != xyes
8948         then
8949                 ADA_SHAREDLIB="$with_ada_sharedlib"
8950         fi
8951 fi
8952
8953 AC_SUBST(ADA_SHAREDLIB)
8954 AC_SUBST(MAKE_ADA_SHAREDLIB)
8955 ])dnl
8956 dnl ---------------------------------------------------------------------------
8957 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
8958 dnl ----------------
8959 dnl Configure-option for dbmalloc.  The optional parameter is used to override
8960 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
8961 AC_DEFUN([CF_WITH_DBMALLOC],[
8962 CF_NO_LEAKS_OPTION(dbmalloc,
8963         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
8964         [USE_DBMALLOC])
8965
8966 if test "$with_dbmalloc" = yes ; then
8967         AC_CHECK_HEADER(dbmalloc.h,
8968                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
8969 fi
8970 ])dnl
8971 dnl ---------------------------------------------------------------------------
8972 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
8973 dnl ---------------
8974 dnl Configure-option for dmalloc.  The optional parameter is used to override
8975 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
8976 AC_DEFUN([CF_WITH_DMALLOC],[
8977 CF_NO_LEAKS_OPTION(dmalloc,
8978         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
8979         [USE_DMALLOC])
8980
8981 if test "$with_dmalloc" = yes ; then
8982         AC_CHECK_HEADER(dmalloc.h,
8983                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
8984 fi
8985 ])dnl
8986 dnl ---------------------------------------------------------------------------
8987 dnl CF_WITH_EXPORT_SYMS version: 3 updated: 2014/12/20 19:16:08
8988 dnl -------------------
8989 dnl Use this with libtool to specify the list of symbols that may be exported.
8990 dnl The input file contains one symbol per line; comments work with "#".
8991 dnl
8992 dnl $1 = basename of the ".sym" file (default $PACKAGE)
8993 AC_DEFUN([CF_WITH_EXPORT_SYMS],
8994 [
8995 AC_MSG_CHECKING(if exported-symbols file should be used)
8996 AC_ARG_WITH(export-syms,
8997         [  --with-export-syms=XXX  limit exported symbols using libtool],
8998         [with_export_syms=$withval],
8999         [with_export_syms=no])
9000 if test "x$with_export_syms" = xyes
9001 then
9002         with_export_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).sym'
9003         AC_SUBST(PACKAGE)
9004 fi
9005 AC_MSG_RESULT($with_export_syms)
9006 if test "x$with_export_syms" != xno
9007 then
9008         EXPORT_SYMS="-export-symbols $with_export_syms"
9009         AC_SUBST(EXPORT_SYMS)
9010 fi
9011 ])dnl
9012 dnl ---------------------------------------------------------------------------
9013 dnl CF_WITH_GPM version: 10 updated: 2017/04/29 18:32:18
9014 dnl -----------
9015 dnl
9016 dnl The option parameter (if neither yes/no) is assumed to be the name of
9017 dnl the gpm library, e.g., for dynamic loading.
9018 AC_DEFUN([CF_WITH_GPM],
9019 [
9020 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
9021 AC_ARG_WITH(gpm,
9022         [  --with-gpm              use Alessandro Rubini's GPM library],
9023         [with_gpm=$withval],
9024         [with_gpm=maybe])
9025 AC_MSG_RESULT($with_gpm)
9026
9027 if test "$with_gpm" != no ; then
9028         AC_CHECK_HEADER(gpm.h,[
9029                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
9030                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
9031                         CF_VERBOSE(assuming we really have GPM library)
9032                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
9033                         with_gpm=yes
9034                 else
9035                         AC_CHECK_LIB(gpm,Gpm_Open,[with_gpm=yes],[
9036                                 if test "$with_gpm" = maybe; then
9037                                         AC_MSG_WARN(Cannot link with GPM library)
9038                                         with_gpm=no
9039                                 else
9040                                         AC_MSG_ERROR(Cannot link with GPM library)
9041                                 fi
9042                         ])
9043                 fi
9044         ],[
9045                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
9046                 with_gpm=no
9047         ])
9048 fi
9049 ])
9050 dnl ---------------------------------------------------------------------------
9051 dnl CF_WITH_LIBTOOL version: 36 updated: 2021/01/01 13:31:04
9052 dnl ---------------
9053 dnl Provide a configure option to incorporate libtool.  Define several useful
9054 dnl symbols for the makefile rules.
9055 dnl
9056 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
9057 dnl macros from libtool.m4 which is in the aclocal directory of automake.
9058 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
9059 dnl But that still does not work properly since the macro is expanded outside
9060 dnl the CF_WITH_LIBTOOL macro:
9061 dnl
9062 dnl     #!/bin/sh
9063 dnl     ACLOCAL=`aclocal --print-ac-dir`
9064 dnl     if test -z "$ACLOCAL" ; then
9065 dnl             echo cannot find aclocal directory
9066 dnl             exit 1
9067 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
9068 dnl             echo cannot find libtool.m4 file
9069 dnl             exit 1
9070 dnl     fi
9071 dnl
9072 dnl     LOCAL=aclocal.m4
9073 dnl     ORIG=aclocal.m4.orig
9074 dnl
9075 dnl     trap "mv $ORIG $LOCAL" 0 1 2 3 15
9076 dnl     rm -f $ORIG
9077 dnl     mv $LOCAL $ORIG
9078 dnl
9079 dnl     # sed the LIBTOOL= assignment to omit the current directory?
9080 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
9081 dnl     cat $ORIG >>$LOCAL
9082 dnl
9083 dnl     autoconf-257 $*
9084 dnl
9085 AC_DEFUN([CF_WITH_LIBTOOL],
9086 [
9087 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
9088 ifdef([AC_PROG_LIBTOOL],,[
9089 LIBTOOL=
9090 ])
9091 # common library maintenance symbols that are convenient for libtool scripts:
9092 LIB_CREATE='${AR} -cr'
9093 LIB_OBJECT='${OBJECTS}'
9094 LIB_SUFFIX=.a
9095 LIB_PREP="$RANLIB"
9096
9097 # symbols used to prop libtool up to enable it to determine what it should be
9098 # doing:
9099 LIB_CLEAN=
9100 LIB_COMPILE=
9101 LIB_LINK='${CC}'
9102 LIB_INSTALL=
9103 LIB_UNINSTALL=
9104
9105 AC_MSG_CHECKING(if you want to build libraries with libtool)
9106 AC_ARG_WITH(libtool,
9107         [  --with-libtool          generate libraries with libtool],
9108         [with_libtool=$withval],
9109         [with_libtool=no])
9110 AC_MSG_RESULT($with_libtool)
9111 if test "$with_libtool" != "no"; then
9112 ifdef([AC_PROG_LIBTOOL],[
9113         # missing_content_AC_PROG_LIBTOOL{{
9114         AC_PROG_LIBTOOL
9115         # missing_content_AC_PROG_LIBTOOL}}
9116 ],[
9117         if test "$with_libtool" != "yes" ; then
9118                 CF_PATH_SYNTAX(with_libtool)
9119                 LIBTOOL=$with_libtool
9120         else
9121                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
9122                 CF_LIBTOOL_VERSION
9123                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
9124                 then
9125                         CF_FORGET_TOOL(LIBTOOL)
9126                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
9127                         CF_LIBTOOL_VERSION
9128                 fi
9129         fi
9130         if test -z "$LIBTOOL" ; then
9131                 AC_MSG_ERROR(Cannot find libtool)
9132         fi
9133 ])dnl
9134         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${libdir} ${LIBTOOL_VERSION} `cut -f1 ${top_srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
9135         LIB_OBJECT='${OBJECTS:.o=.lo}'
9136         LIB_SUFFIX=.la
9137         LIB_CLEAN='${LIBTOOL} --mode=clean'
9138         LIB_COMPILE='${LIBTOOL} --mode=compile'
9139         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
9140         LIB_INSTALL='${LIBTOOL} --mode=install'
9141         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
9142         LIB_PREP=:
9143
9144         CF_CHECK_LIBTOOL_VERSION
9145
9146         # special hack to add -no-undefined (which libtool should do for itself)
9147         LT_UNDEF=
9148         case "$cf_cv_system_name" in
9149         (cygwin*|msys*|mingw32*|os2*|uwin*|aix[[4-7]])
9150                 LT_UNDEF=-no-undefined
9151                 ;;
9152         esac
9153         AC_SUBST([LT_UNDEF])
9154
9155         # special hack to add --tag option for C++ compiler
9156         case "$cf_cv_libtool_version" in
9157         (1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*)
9158                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
9159                 LIBTOOL="$LIBTOOL --tag=CC"
9160                 ;;
9161         (*)
9162                 LIBTOOL_CXX="$LIBTOOL"
9163                 ;;
9164         esac
9165 else
9166         LIBTOOL=""
9167         LIBTOOL_CXX=""
9168 fi
9169
9170 test -z "$LIBTOOL" && ECHO_LT=
9171
9172 AC_SUBST(LIBTOOL)
9173 AC_SUBST(LIBTOOL_CXX)
9174 AC_SUBST(LIBTOOL_OPTS)
9175
9176 AC_SUBST(LIB_CREATE)
9177 AC_SUBST(LIB_OBJECT)
9178 AC_SUBST(LIB_SUFFIX)
9179 AC_SUBST(LIB_PREP)
9180
9181 AC_SUBST(LIB_CLEAN)
9182 AC_SUBST(LIB_COMPILE)
9183 AC_SUBST(LIB_LINK)
9184 AC_SUBST(LIB_INSTALL)
9185 AC_SUBST(LIB_UNINSTALL)
9186
9187 ])dnl
9188 dnl ---------------------------------------------------------------------------
9189 dnl CF_WITH_LIBTOOL_OPTS version: 4 updated: 2015/04/17 21:13:04
9190 dnl --------------------
9191 dnl Allow user to pass additional libtool options into the library creation
9192 dnl and link steps.  The main use for this is to do something like
9193 dnl     ./configure --with-libtool-opts=-static
9194 dnl to get the same behavior as automake-flavored
9195 dnl     ./configure --enable-static
9196 AC_DEFUN([CF_WITH_LIBTOOL_OPTS],[
9197 AC_MSG_CHECKING(for additional libtool options)
9198 AC_ARG_WITH(libtool-opts,
9199         [  --with-libtool-opts=XXX specify additional libtool options],
9200         [with_libtool_opts=$withval],
9201         [with_libtool_opts=no])
9202 AC_MSG_RESULT($with_libtool_opts)
9203
9204 case .$with_libtool_opts in
9205 (.yes|.no|.)
9206         ;;
9207 (*)
9208         LIBTOOL_OPTS="$LIBTOOL_OPTS $with_libtool_opts"
9209         ;;
9210 esac
9211
9212 AC_SUBST(LIBTOOL_OPTS)
9213 ])dnl
9214 dnl ---------------------------------------------------------------------------
9215 dnl CF_WITH_LIB_BASENAME version: 1 updated: 2020/03/07 20:05:14
9216 dnl --------------------
9217 dnl Allow for overriding the basename of a library, i.e., the part to which
9218 dnl prefixes/suffixes are attached.
9219 dnl
9220 dnl $1 = variable to set
9221 dnl $2 = option name
9222 dnl $3 = default basename for library, if omitted use $2
9223 AC_DEFUN([CF_WITH_LIB_BASENAME],
9224 [
9225 AC_MSG_CHECKING(for desired basename for $2 library)
9226 AC_ARG_WITH($2-libname,
9227         [  --with-$2-libname=XXX override ifelse($3,,$2,$3) basename of library],
9228         [with_lib_basename=$withval],
9229         [with_lib_basename=ifelse($3,,$2,$3)])
9230 $1="$with_lib_basename"
9231
9232 case "x[$]$1" in
9233 (x|xno|xnone|xyes)
9234         $1=ifelse($3,,$2,$3)
9235         ;;
9236 (*)
9237         ;;
9238 esac
9239
9240 AC_MSG_RESULT([$]$1)
9241 AC_SUBST($1)
9242 ])dnl
9243 dnl ---------------------------------------------------------------------------
9244 dnl CF_WITH_LIB_PREFIX version: 2 updated: 2021/01/01 16:53:59
9245 dnl ------------------
9246 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
9247 dnl "lib" prefix, e.g., because it used the dll naming convention.
9248 dnl
9249 dnl $1 = variable to set
9250 AC_DEFUN([CF_WITH_LIB_PREFIX],
9251 [
9252 AC_MSG_CHECKING(if you want to have a library-prefix)
9253 AC_ARG_WITH(lib-prefix,
9254         [  --with-lib-prefix       override library-prefix],
9255         [with_lib_prefix=$withval],
9256         [with_lib_prefix=auto])
9257 AC_MSG_RESULT($with_lib_prefix)
9258
9259 if test "$with_lib_prefix" = auto
9260 then
9261         CF_LIB_PREFIX($1)
9262 elif test "$with_lib_prefix" = no
9263 then
9264         LIB_PREFIX=
9265 else
9266         LIB_PREFIX=$with_lib_prefix
9267 fi
9268 ])dnl
9269 dnl ---------------------------------------------------------------------------
9270 dnl CF_WITH_PATH version: 12 updated: 2021/09/04 06:35:04
9271 dnl ------------
9272 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
9273 dnl defaulting to yes/no.
9274 dnl
9275 dnl $1 = option name
9276 dnl $2 = help-text
9277 dnl $3 = environment variable to set
9278 dnl $4 = default value, shown in the help-message, must be a constant
9279 dnl $5 = default value, if it is an expression & cannot be in the help-message
9280 dnl
9281 AC_DEFUN([CF_WITH_PATH],
9282 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
9283 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
9284 if ifelse([$5],,true,[test -n "$5"]) ; then
9285 CF_PATH_SYNTAX(withval)
9286 fi
9287 eval $3="$withval"
9288 AC_SUBST($3)dnl
9289 ])dnl
9290 dnl ---------------------------------------------------------------------------
9291 dnl CF_WITH_PATHLIST version: 13 updated: 2021/09/04 06:35:04
9292 dnl ----------------
9293 dnl Process an option specifying a list of colon-separated paths.
9294 dnl
9295 dnl $1 = option name
9296 dnl $2 = help-text
9297 dnl $3 = environment variable to set
9298 dnl $4 = default value, shown in the help-message, must be a constant
9299 dnl $5 = default value, if it is an expression & cannot be in the help-message
9300 dnl $6 = flag to tell if we want to define or substitute
9301 dnl
9302 AC_DEFUN([CF_WITH_PATHLIST],[
9303 AC_REQUIRE([CF_PATHSEP])
9304 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
9305 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
9306
9307 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
9308 cf_dst_path=
9309 for cf_src_path in $withval
9310 do
9311   CF_PATH_SYNTAX(cf_src_path)
9312   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
9313   cf_dst_path="${cf_dst_path}${cf_src_path}"
9314 done
9315 IFS="$ac_save_ifs"
9316
9317 ifelse($6,define,[
9318 # Strip single quotes from the value, e.g., when it was supplied as a literal
9319 # for $4 or $5.
9320 case "$cf_dst_path" in
9321 (\'*)
9322   cf_dst_path="`echo "$cf_dst_path" |sed -e s/\'// -e s/\'\$//`"
9323   ;;
9324 esac
9325 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
9326 ])
9327
9328 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
9329 # so we have to check/work around.  We do prefer the result of "eval"...
9330 eval cf_dst_eval="$cf_dst_path"
9331 case "x$cf_dst_eval" in
9332 (xNONE*)
9333         $3=$cf_dst_path
9334         ;;
9335 (*)
9336         $3="$cf_dst_eval"
9337         ;;
9338 esac
9339 AC_SUBST($3)dnl
9340
9341 ])dnl
9342 dnl ---------------------------------------------------------------------------
9343 dnl CF_WITH_PATH_PROG version: 1 updated: 2019/06/30 19:44:43
9344 dnl -----------------
9345 dnl Check for a given program, like CF_PATH_PROG, but allow override using a
9346 dnl "--with-xxx" option.
9347 dnl
9348 dnl Parameters:
9349 dnl             $1 = environment variable to set/update
9350 dnl             $2 = program name
9351 dnl             $3 = help-text
9352 dnl             $4 = $PATH
9353 AC_DEFUN([CF_WITH_PATH_PROG],[
9354 AC_ARG_WITH($2-path,
9355         [  --with-$2-path=XXX     specify path of $2 ifelse($3,,,$3)],
9356         [AC_MSG_CHECKING(for $2 program ifelse($3,,,$3))
9357                 $1=$withval
9358                 AC_MSG_RESULT([$]$1)
9359                 CF_PATH_SYNTAX($1)
9360         ],
9361         [CF_PATH_PROG($1,$2,,ifelse($4,,,$4))
9362                 if test -z "[$]$1"
9363                 then
9364                         AC_MSG_WARN(no $2 program found ifelse($3,,,$3))
9365                 fi
9366         ])
9367 ])
9368 dnl ---------------------------------------------------------------------------
9369 dnl CF_WITH_PCRE2 version: 6 updated: 2021/08/11 20:35:34
9370 dnl -------------
9371 dnl Add PCRE2 (Perl-compatible regular expressions v2) to the build if it is
9372 dnl available and the user requests it.  Assume the application will otherwise
9373 dnl use the POSIX interface.
9374 dnl
9375 dnl TODO allow $withval to specify package location
9376 AC_DEFUN([CF_WITH_PCRE2],
9377 [
9378 AC_REQUIRE([CF_PKG_CONFIG])
9379
9380 AC_MSG_CHECKING(if you want to use PCRE2 for regular-expressions)
9381 AC_ARG_WITH(pcre2,
9382         [  --with-pcre2            use PCRE2 for regular-expressions])
9383 test -z "$with_pcre2" && with_pcre2=no
9384 AC_MSG_RESULT($with_pcre2)
9385
9386 if test "x$with_pcre2" != xno ; then
9387         cf_with_pcre2_ok=no
9388         for cf_with_pcre2 in libpcre2 libpcre2-posix libpcre
9389         do
9390                 CF_TRY_PKG_CONFIG($cf_with_pcre2,[cf_with_pcre2_ok=yes; break])
9391         done
9392         cf_with_pcre2_ok=yes || AC_MSG_ERROR(Cannot find PCRE2 library)
9393
9394         AC_DEFINE(HAVE_LIB_PCRE2,1,[Define to 1 if we can/should compile with the PCRE2 library])
9395
9396         # if pkgconfig gave no results, look for the libraries directly
9397         case "$LIBS" in
9398         (*pcre2-posix*|*pcreposix*)
9399                 ;;
9400         (*)
9401                 AC_CHECK_LIB(pcre2-posix,regcomp,[
9402                         CF_ADD_LIB(pcre2-posix)],
9403                         [AC_CHECK_LIB(pcreposix,regcomp,[
9404                          CF_ADD_LIB(pcreposix)
9405                         ],[AC_MSG_ERROR(Cannot find PCRE2 POSIX library)])])
9406                 ;;
9407         esac
9408
9409         # either way, check for the library header files
9410         AC_CHECK_HEADERS(pcre2posix.h pcreposix.h)
9411         AC_CHECK_FUNCS(PCRE2regcomp)
9412 fi
9413 ])dnl
9414 dnl ---------------------------------------------------------------------------
9415 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 20 updated: 2022/01/29 17:03:42
9416 dnl -------------------------
9417 dnl Allow the choice of the pkg-config library directory to be overridden.
9418 dnl
9419 dnl pkg-config uses a search-list built from these colon-separated lists of
9420 dnl directories:
9421 dnl a) $PKG_CONFIG_PATH (tested first, added if set)
9422 dnl b) $PKG_CONFIG_LIBDIR (tested second, added if set)
9423 dnl c) builtin-list (added if $PKG_CONFIG_LIBDIR is not set)
9424 dnl
9425 dnl pkgconf (used with some systems such as FreeBSD in place of pkg-config)
9426 dnl optionally ignores $PKG_CONFIG_LIBDIR.
9427 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
9428
9429 case "$PKG_CONFIG" in
9430 (no|none|yes)
9431         AC_MSG_CHECKING(for pkg-config library directory)
9432         ;;
9433 (*)
9434         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
9435         ;;
9436 esac
9437
9438 # if $PKG_CONFIG_LIBDIR is set, try to use that
9439 cf_search_path=`echo "$PKG_CONFIG_LIBDIR" | sed -e 's/:/ /g' -e 's,^[[  ]]*,,'`
9440
9441 # if the option is used, let that override.  otherwise default to "libdir"
9442 AC_ARG_WITH(pkg-config-libdir,
9443         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
9444         [cf_search_path=$withval],
9445         [test "x$PKG_CONFIG" != xnone && test -z "$cf_search_path" && cf_search_path=libdir])
9446
9447 case "x$cf_search_path" in
9448 (xlibdir)
9449         PKG_CONFIG_LIBDIR='${libdir}/pkgconfig'
9450         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
9451         cf_search_path=
9452         ;;
9453 (x)
9454         ;;
9455 (x/*\ *)
9456         PKG_CONFIG_LIBDIR=
9457         ;;
9458 (x/*)
9459         PKG_CONFIG_LIBDIR="$cf_search_path"
9460         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
9461         cf_search_path=
9462         ;;
9463 (xyes|xauto)
9464         AC_MSG_RESULT(auto)
9465         cf_search_path=
9466         # Look for the library directory using the same prefix as the executable
9467         AC_MSG_CHECKING(for search-list)
9468         if test "x$PKG_CONFIG" != xnone
9469         then
9470                 # works for pkg-config since version 0.24 (2009)
9471                 # works for pkgconf since version 0.8.3 (2012)
9472                 for cf_pkg_program in \
9473                         `echo "$PKG_CONFIG" | sed -e 's,^.*/,,'` \
9474                         pkg-config \
9475                         pkgconf
9476                 do
9477                         cf_search_path=`"$PKG_CONFIG" --variable=pc_path "$cf_pkg_program" 2>/dev/null | tr : ' '`
9478                         test -n "$cf_search_path" && break
9479                 done
9480
9481                 # works for pkg-config since import in 2005 of original 2001 HP code.
9482                 test -z "$cf_search_path" && \
9483                 cf_search_path=`
9484                 "$PKG_CONFIG" --debug --exists no-such-package 2>&1 | $AWK "\
9485 /^Scanning directory (#[1-9][0-9]* )?'.*'$/{ \
9486         sub(\"^[[^']]*'\",\"\"); \
9487         sub(\"'.*\",\"\"); \
9488         printf \" %s\", \\[$]0; } \
9489 { next; } \
9490 "`
9491         fi
9492
9493         AC_MSG_RESULT($cf_search_path)
9494         ;;
9495 (*)
9496         AC_MSG_ERROR(Unexpected option value: $cf_search_path)
9497         ;;
9498 esac
9499
9500 if test -n "$cf_search_path"
9501 then
9502         AC_MSG_CHECKING(for first directory)
9503         cf_pkg_config_path=none
9504         for cf_config in $cf_search_path
9505         do
9506                 if test -d "$cf_config"
9507                 then
9508                         cf_pkg_config_path=$cf_config
9509                         break
9510                 fi
9511         done
9512         AC_MSG_RESULT($cf_pkg_config_path)
9513
9514         if test "x$cf_pkg_config_path" != xnone ; then
9515                 # limit this to the first directory found
9516                 PKG_CONFIG_LIBDIR="$cf_pkg_config_path"
9517         fi
9518
9519         if test -z "$PKG_CONFIG_LIBDIR" && test -n "$cf_search_path"
9520         then
9521                 AC_MSG_CHECKING(for workaround)
9522                 if test "$prefix" = "NONE" ; then
9523                         cf_prefix="$ac_default_prefix"
9524                 else
9525                         cf_prefix="$prefix"
9526                 fi
9527                 eval cf_libdir=$libdir
9528                 cf_libdir=`echo "$cf_libdir" | sed -e "s,^NONE,$cf_prefix,"`
9529                 cf_backup=
9530                 for cf_config in $cf_search_path
9531                 do
9532                         case $cf_config in
9533                         $cf_libdir/pkgconfig)
9534                                 PKG_CONFIG_LIBDIR=$cf_libdir/pkgconfig
9535                                 break
9536                                 ;;
9537                         *)
9538                                 test -z "$cf_backup" && cf_backup=$cf_config
9539                                 ;;
9540                         esac
9541                 done
9542                 test -z "$PKG_CONFIG_LIBDIR" && PKG_CONFIG_LIBDIR=$cf_backup
9543                 AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
9544         fi
9545 fi
9546
9547 AC_SUBST(PKG_CONFIG_LIBDIR)
9548 ])dnl
9549 dnl ---------------------------------------------------------------------------
9550 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
9551 dnl ---------------
9552 dnl Check for POSIX thread library.
9553 AC_DEFUN([CF_WITH_PTHREAD],
9554 [
9555 AC_MSG_CHECKING(if you want to link with the pthread library)
9556 AC_ARG_WITH(pthread,
9557         [  --with-pthread          use POSIX thread library],
9558         [with_pthread=$withval],
9559         [with_pthread=no])
9560 AC_MSG_RESULT($with_pthread)
9561
9562 if test "$with_pthread" != no ; then
9563         AC_CHECK_HEADER(pthread.h,[
9564         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
9565
9566         for cf_lib_pthread in pthread c_r
9567         do
9568             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
9569             cf_save_LIBS="$LIBS"
9570             CF_ADD_LIB($cf_lib_pthread)
9571             AC_TRY_LINK([
9572 #include <pthread.h>
9573 ],[
9574                 int rc = pthread_create(0,0,0,0);
9575                 int r2 = pthread_mutexattr_settype(0, 0);
9576 ],[with_pthread=yes],[with_pthread=no])
9577             LIBS="$cf_save_LIBS"
9578             AC_MSG_RESULT($with_pthread)
9579             test "$with_pthread" = yes && break
9580         done
9581
9582         if test "$with_pthread" = yes ; then
9583             CF_ADD_LIB($cf_lib_pthread)
9584             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
9585         else
9586             AC_MSG_ERROR(Cannot link with pthread library)
9587         fi
9588         ])
9589 fi
9590 ])
9591 dnl ---------------------------------------------------------------------------
9592 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
9593 dnl -------------------
9594 dnl Allow library's release-version to be overridden.  Generally this happens when a
9595 dnl packager has incremented the release-version past that used in the original package,
9596 dnl and wishes to keep doing this.
9597 dnl
9598 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
9599 dnl and {package}_MINOR symbols
9600 dnl symbol.
9601 AC_DEFUN([CF_WITH_REL_VERSION],[
9602 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
9603 AC_ARG_WITH(rel-version,
9604 [  --with-rel-version=XXX  override derived release version],
9605 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
9606  cf_cv_rel_version=$withval])
9607 ifelse($1,,[
9608  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
9609 ],[
9610  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
9611  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
9612  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
9613  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
9614 ])
9615 ])dnl
9616 dnl ---------------------------------------------------------------------------
9617 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
9618 dnl ----------------
9619 dnl If we can compile with sysmouse, make it available unless it is not wanted.
9620 AC_DEFUN([CF_WITH_SYSMOUSE],[
9621 # not everyone has "test -c"
9622 if test -c /dev/sysmouse 2>/dev/null ; then
9623 AC_MSG_CHECKING(if you want to use sysmouse)
9624 AC_ARG_WITH(sysmouse,
9625         [  --with-sysmouse         use sysmouse (FreeBSD console)],
9626         [cf_with_sysmouse=$withval],
9627         [cf_with_sysmouse=maybe])
9628         if test "$cf_with_sysmouse" != no ; then
9629         AC_TRY_COMPILE([
9630 #include <osreldate.h>
9631 #if (__FreeBSD_version >= 400017)
9632 #include <sys/consio.h>
9633 #include <sys/fbio.h>
9634 #else
9635 #include <machine/console.h>
9636 #endif
9637 ],[
9638         struct mouse_info the_mouse;
9639         ioctl(0, CONS_MOUSECTL, &the_mouse);
9640 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
9641         fi
9642 AC_MSG_RESULT($cf_with_sysmouse)
9643 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
9644 fi
9645 ])dnl
9646 dnl ---------------------------------------------------------------------------
9647 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
9648 dnl ---------------
9649 dnl For testing, override the derived host system-type which is used to decide
9650 dnl things such as the linker commands used to build shared libraries.  This is
9651 dnl normally chosen automatically based on the type of system which you are
9652 dnl building on.  We use it for testing the configure script.
9653 dnl
9654 dnl This is different from the --host option: it is used only for testing parts
9655 dnl of the configure script which would not be reachable with --host since that
9656 dnl relies on the build environment being real, rather than mocked up.
9657 AC_DEFUN([CF_WITH_SYSTYPE],[
9658 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
9659 AC_ARG_WITH(system-type,
9660         [  --with-system-type=XXX  test: override derived host system-type],
9661 [AC_MSG_WARN(overriding system type to $withval)
9662         cf_cv_system_name=$withval
9663         host_os=$withval
9664 ])
9665 ])dnl
9666 dnl ---------------------------------------------------------------------------
9667 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
9668 dnl ----------------
9669 AC_DEFUN([CF_WITH_VALGRIND],[
9670 CF_NO_LEAKS_OPTION(valgrind,
9671         [  --with-valgrind         test: use valgrind],
9672         [USE_VALGRIND])
9673 ])dnl
9674 dnl ---------------------------------------------------------------------------
9675 dnl CF_WITH_VERSIONED_SYMS version: 10 updated: 2021/01/04 18:48:01
9676 dnl ----------------------
9677 dnl Use this when building shared library with ELF, to markup symbols with the
9678 dnl version identifier from the given input file.  Generally that identifier is
9679 dnl the same as the SONAME at which the symbol was first introduced.
9680 dnl
9681 dnl $1 = basename of the ".map" file (default $PACKAGE)
9682 AC_DEFUN([CF_WITH_VERSIONED_SYMS],
9683 [AC_REQUIRE([AC_PROG_FGREP])dnl
9684 AC_REQUIRE([AC_PROG_EGREP])dnl
9685
9686 AC_MSG_CHECKING(if versioned-symbols file should be used)
9687 AC_ARG_WITH(versioned-syms,
9688         [  --with-versioned-syms=X markup versioned symbols using ld],
9689         [with_versioned_syms=$withval],
9690         [with_versioned_syms=no])
9691 case "x$with_versioned_syms" in
9692 (xyes)
9693         with_versioned_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).map'
9694         AC_SUBST(PACKAGE)
9695         ;;
9696 (xno)
9697         ;;
9698 (x/*)
9699         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
9700         ;;
9701 (*)
9702         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
9703         with_versioned_syms=`pwd`/"$with_versioned_syms"
9704         ;;
9705 esac
9706 AC_MSG_RESULT($with_versioned_syms)
9707
9708 RESULTING_SYMS=
9709 VERSIONED_SYMS=
9710 WILDCARD_SYMS=
9711
9712 if test "x$with_versioned_syms" != xno
9713 then
9714         RESULTING_SYMS=$with_versioned_syms
9715         case "x$MK_SHARED_LIB" in
9716         (*-Wl,*)
9717                 VERSIONED_SYMS="-Wl,--version-script,\${RESULTING_SYMS}"
9718                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-Wl,%\\[$]{VERSIONED_SYMS} -Wl,%"`
9719                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
9720                 ;;
9721         (*-dy\ *)
9722                 VERSIONED_SYMS="-Wl,-M,\${RESULTING_SYMS}"
9723                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-dy%\\[$]{VERSIONED_SYMS} -dy%"`
9724                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
9725                 ;;
9726         (*)
9727                 AC_MSG_WARN(this system does not support versioned-symbols)
9728                 ;;
9729         esac
9730
9731         # Linux ld can selectively override scope, e.g., of symbols beginning with
9732         # "_" by first declaring some as global, and then using a wildcard to
9733         # declare the others as local.  Some other loaders cannot do this.  Check
9734         # by constructing a (very) simple shared library and inspecting its
9735         # symbols.
9736         if test "x$VERSIONED_SYMS" != "x"
9737         then
9738                 AC_MSG_CHECKING(if wildcards can be used to selectively omit symbols)
9739                 WILDCARD_SYMS=no
9740
9741                 # make sources
9742                 rm -f conftest.*
9743
9744                 cat >conftest.ver <<EOF
9745 module_1.0 {
9746 global:
9747         globalf1;
9748 local:
9749         localf1;
9750 };
9751 module_2.0 {
9752 global:
9753         globalf2;
9754 local:
9755         localf2;
9756         _*;
9757 } module_1.0;
9758 submodule_1.0 {
9759 global:
9760         subglobalf1;
9761         _ismissing;
9762 local:
9763         sublocalf1;
9764 };
9765 submodule_2.0 {
9766 global:
9767         subglobalf2;
9768 local:
9769         sublocalf2;
9770         _*;
9771 } submodule_1.0;
9772 EOF
9773                 cat >conftest.$ac_ext <<EOF
9774 #line __oline__ "configure"
9775 int     _ismissing(void) { return 1; }
9776 int     _localf1(void) { return 1; }
9777 int     _localf2(void) { return 2; }
9778 int     globalf1(void) { return 1; }
9779 int     globalf2(void) { return 2; }
9780 int     _sublocalf1(void) { return 1; }
9781 int     _sublocalf2(void) { return 2; }
9782 int     subglobalf1(void) { return 1; }
9783 int     subglobalf2(void) { return 2; }
9784 EOF
9785                 cat >conftest.mk <<EOF
9786 CC=${CC}
9787 CFLAGS=${CFLAGS}
9788 CPPFLAGS=${CPPFLAGS}
9789 LDFLAGS=${LDFLAGS}
9790 LIBS=${LIBS}
9791 VERSIONED_SYMS=${VERSIONED_SYMS}
9792 RESULTING_SYMS=conftest.ver
9793 MK_SHARED_LIB=${MK_SHARED_LIB}
9794 conftest.so: conftest.$ac_cv_objext
9795                 \$(MK_SHARED_LIB) conftest.$ac_cv_objext
9796 EOF
9797
9798                 # compile source, make library
9799                 if make -f conftest.mk 2>&AC_FD_CC >/dev/null
9800                 then
9801                         # test for missing symbol in either Data or Text section
9802                         cf_missing="`nm -P conftest.so 2>&AC_FD_CC |${FGREP-fgrep} _ismissing | ${EGREP-egrep} '[[      ]][[DT]][[      ]]'`"
9803                         test -n "$cf_missing" && WILDCARD_SYMS=yes
9804                 fi
9805                 AC_MSG_RESULT($WILDCARD_SYMS)
9806                 rm -f conftest.*
9807         fi
9808 fi
9809 AC_SUBST(RESULTING_SYMS)
9810 AC_SUBST(VERSIONED_SYMS)
9811 AC_SUBST(WILDCARD_SYMS)
9812 ])dnl
9813 dnl ---------------------------------------------------------------------------
9814 dnl CF_WITH_X11_RGB version: 2 updated: 2019/12/31 08:53:54
9815 dnl ---------------
9816 dnl Handle configure option "--with-x11-rgb", setting these shell
9817 dnl variables:
9818 dnl
9819 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
9820 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
9821 dnl
9822 dnl Most Linux's use this:
9823 dnl     /usr/share/X11/rgb.txt
9824 dnl Debian uses this:
9825 dnl     /etc/X11/rgb.txt
9826 dnl DragonFlyBSD ports uses this:
9827 dnl     /usr/pkg/lib/X11/rgb.txt
9828 dnl FreeBSD ports use these:
9829 dnl     /usr/local/lib/X11/rgb.txt
9830 dnl     /usr/local/share/X11/rgb.txt
9831 dnl Mandriva has these:
9832 dnl     /usr/lib/X11/rgb.txt
9833 dnl     /usr/lib64/X11/rgb.txt
9834 dnl NetBSD has these
9835 dnl     /usr/X11R7/lib/X11/rgb.txt
9836 dnl OpenSolaris uses
9837 dnl     32-bit:
9838 dnl     /usr/X11/etc/X11/rgb.txt
9839 dnl     /usr/X11/share/X11/rgb.txt
9840 dnl     /usr/X11/lib/X11/rgb.txt
9841 dnl OSX uses
9842 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
9843 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
9844 dnl     64-bit:
9845 dnl     /usr/X11/etc/X11/rgb.txt
9846 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
9847 dnl     /usr/X11/lib/amd64/X11/rgb.txt
9848 dnl Solaris10 uses (in this order):
9849 dnl     /usr/openwin/lib/X11/rgb.txt
9850 dnl     /usr/X11/lib/X11/rgb.txt
9851 AC_DEFUN([CF_WITH_X11_RGB],[
9852 AC_MSG_CHECKING(for X11 rgb file)
9853 AC_ARG_WITH(x11-rgb,
9854         [  --with-x11-rgb=FILE   file containing X11 rgb information (EPREFIX/lib/X11/rgb.txt)],
9855         [RGB_PATH=$withval],
9856         [RGB_PATH=auto])
9857
9858 if test "x[$]RGB_PATH" = xauto
9859 then
9860         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
9861         for cf_path in \
9862                 /opt/local/share/X11/rgb.txt \
9863                 /opt/X11/share/X11/rgb.txt \
9864                 /usr/share/X11/rgb.txt \
9865                 /usr/X11/share/X11/rgb.txt \
9866                 /usr/X11/lib/X11/rgb.txt \
9867                 /usr/lib/X11/rgb.txt \
9868                 /etc/X11/rgb.txt \
9869                 /usr/pkg/lib/X11/rgb.txt \
9870                 /usr/X11R7/lib/X11/rgb.txt \
9871                 /usr/X11R6/lib/X11/rgb.txt \
9872                 /usr/X11R5/lib/X11/rgb.txt \
9873                 /usr/X11R4/lib/X11/rgb.txt \
9874                 /usr/local/lib/X11/rgb.txt \
9875                 /usr/local/share/X11/rgb.txt \
9876                 /usr/lib64/X11/rgb.txt
9877         do
9878                 if test -f "$cf_path" ; then
9879                         RGB_PATH="$cf_path"
9880                         break
9881                 fi
9882         done
9883 else
9884         cf_path=$RGB_PATH
9885         CF_PATH_SYNTAX(cf_path)
9886 fi
9887
9888 AC_MSG_RESULT($RGB_PATH)
9889 AC_SUBST(RGB_PATH)
9890 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path",[Define to the full pathname of rgb.txt])
9891
9892 no_x11_rgb=
9893 if test "$RGB_PATH" = no
9894 then
9895         no_x11_rgb="#"
9896 fi
9897 AC_SUBST(no_x11_rgb)
9898 ])dnl
9899 dnl ---------------------------------------------------------------------------
9900 dnl CF_XOPEN_SOURCE version: 62 updated: 2022/10/02 19:55:56
9901 dnl ---------------
9902 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
9903 dnl or adapt to the vendor's definitions to get equivalent functionality,
9904 dnl without losing the common non-POSIX features.
9905 dnl
9906 dnl Parameters:
9907 dnl     $1 is the nominal value for _XOPEN_SOURCE
9908 dnl     $2 is the nominal value for _POSIX_C_SOURCE
9909 AC_DEFUN([CF_XOPEN_SOURCE],[
9910 AC_REQUIRE([AC_CANONICAL_HOST])
9911 AC_REQUIRE([CF_POSIX_VISIBLE])
9912
9913 if test "$cf_cv_posix_visible" = no; then
9914
9915 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
9916 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
9917 cf_xopen_source=
9918
9919 case "$host_os" in
9920 (aix[[4-7]]*)
9921         cf_xopen_source="-D_ALL_SOURCE"
9922         ;;
9923 (msys)
9924         cf_XOPEN_SOURCE=600
9925         ;;
9926 (darwin[[0-8]].*)
9927         cf_xopen_source="-D_APPLE_C_SOURCE"
9928         ;;
9929 (darwin*)
9930         cf_xopen_source="-D_DARWIN_C_SOURCE"
9931         cf_XOPEN_SOURCE=
9932         ;;
9933 (freebsd*|dragonfly*|midnightbsd*)
9934         # 5.x headers associate
9935         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
9936         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
9937         cf_POSIX_C_SOURCE=200112L
9938         cf_XOPEN_SOURCE=600
9939         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
9940         ;;
9941 (hpux11*)
9942         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
9943         ;;
9944 (hpux*)
9945         cf_xopen_source="-D_HPUX_SOURCE"
9946         ;;
9947 (irix[[56]].*)
9948         cf_xopen_source="-D_SGI_SOURCE"
9949         cf_XOPEN_SOURCE=
9950         ;;
9951 (linux*gnu|linux*gnuabi64|linux*gnuabin32|linux*gnueabi|linux*gnueabihf|linux*gnux32|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
9952         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
9953         ;;
9954 (minix*)
9955         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
9956         ;;
9957 (mirbsd*)
9958         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
9959         cf_XOPEN_SOURCE=
9960         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
9961         ;;
9962 (netbsd*)
9963         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
9964         ;;
9965 (openbsd[[6-9]]*)
9966         # OpenBSD 6.x has broken locale support, both compile-time and runtime.
9967         # see https://www.mail-archive.com/bugs@openbsd.org/msg13200.html
9968         # Abusing the conformance level is a workaround.
9969         AC_MSG_WARN(this system does not provide usable locale support)
9970         cf_xopen_source="-D_BSD_SOURCE"
9971         cf_XOPEN_SOURCE=700
9972         ;;
9973 (openbsd[[4-5]]*)
9974         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
9975         cf_xopen_source="-D_BSD_SOURCE"
9976         cf_XOPEN_SOURCE=600
9977         ;;
9978 (openbsd*)
9979         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
9980         ;;
9981 (osf[[45]]*)
9982         cf_xopen_source="-D_OSF_SOURCE"
9983         ;;
9984 (nto-qnx*)
9985         cf_xopen_source="-D_QNX_SOURCE"
9986         ;;
9987 (sco*)
9988         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
9989         ;;
9990 (solaris2.*)
9991         cf_xopen_source="-D__EXTENSIONS__"
9992         cf_cv_xopen_source=broken
9993         ;;
9994 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
9995         cf_XOPEN_SOURCE=
9996         cf_POSIX_C_SOURCE=
9997         ;;
9998 (*)
9999         CF_TRY_XOPEN_SOURCE
10000         cf_save_xopen_cppflags="$CPPFLAGS"
10001         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
10002         # Some of these niche implementations use copy/paste, double-check...
10003         CF_VERBOSE(checking if _POSIX_C_SOURCE inteferes)
10004         AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,,[
10005                 AC_MSG_WARN(_POSIX_C_SOURCE definition is not usable)
10006                 CPPFLAGS="$cf_save_xopen_cppflags"])
10007         ;;
10008 esac
10009
10010 if test -n "$cf_xopen_source" ; then
10011         CF_APPEND_CFLAGS($cf_xopen_source,true)
10012 fi
10013
10014 dnl In anything but the default case, we may have system-specific setting
10015 dnl which is still not guaranteed to provide all of the entrypoints that
10016 dnl _XOPEN_SOURCE would yield.
10017 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
10018         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
10019         AC_TRY_COMPILE([#include <stdlib.h>],[
10020 #ifndef _XOPEN_SOURCE
10021 make an error
10022 #endif],
10023         [cf_XOPEN_SOURCE_set=yes],
10024         [cf_XOPEN_SOURCE_set=no])
10025         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
10026         if test "$cf_XOPEN_SOURCE_set" = yes
10027         then
10028                 AC_TRY_COMPILE([#include <stdlib.h>],[
10029 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
10030 make an error
10031 #endif],
10032                 [cf_XOPEN_SOURCE_set_ok=yes],
10033                 [cf_XOPEN_SOURCE_set_ok=no])
10034                 if test "$cf_XOPEN_SOURCE_set_ok" = no
10035                 then
10036                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
10037                 fi
10038         else
10039                 CF_TRY_XOPEN_SOURCE
10040         fi
10041 fi
10042 fi # cf_cv_posix_visible
10043 ])
10044 dnl ---------------------------------------------------------------------------
10045 dnl CF__SED_TRIMBLANKS version: 1 updated: 2021/01/02 09:31:20
10046 dnl ------------------
10047 dnl Trim something using sed, then trim extra whitespace
10048 dnl $1 = extra parameters, e.g., in CF_STRIP_G_OPT
10049 define([CF__SED_TRIMBLANKS],[sed ifelse($1,,,[$1] )-e 's%[[     ]]% %g' -e 's% [[ ]]*% %g' -e 's%^ %%' -e 's% [$]%%'])dnl
10050 dnl ---------------------------------------------------------------------------
10051 dnl CF__XOPEN_SOURCE_BODY version: 1 updated: 2022/09/10 15:17:35
10052 dnl ---------------------
10053 dnl body of test when test-compiling for _XOPEN_SOURCE check
10054 define([CF__XOPEN_SOURCE_BODY],
10055 [
10056 #ifndef _XOPEN_SOURCE
10057 make an error
10058 #endif
10059 ])
10060 dnl ---------------------------------------------------------------------------
10061 dnl CF__XOPEN_SOURCE_HEAD version: 1 updated: 2022/09/10 15:17:03
10062 dnl ---------------------
10063 dnl headers to include when test-compiling for _XOPEN_SOURCE check
10064 define([CF__XOPEN_SOURCE_HEAD],
10065 [
10066 #include <stdlib.h>
10067 #include <string.h>
10068 #include <sys/types.h>
10069 ])