configure.in

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2023,2024 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: configure.in,v 1.774 2024/01/19 11:22:46 tom Exp $
  33 dnl Process this file with autoconf to produce a configure script.
  34 dnl
  35 dnl For additional information, see
  36 dnl     https://invisible-island.net/autoconf/
  37 dnl     https://invisible-island.net/autoconf/my-autoconf.html
  38 dnl
  39 dnl ---------------------------------------------------------------------------
  40 AC_PREREQ(2.52.20210101)
  41 AC_REVISION($Revision: 1.774 $)
  42 AC_INIT(ncurses/base/lib_initscr.c)
  43 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  44
  45 AC_DEFUN([AC_PATH_XTRA],[])dnl ignore dependencies on this
  46
  47 CF_TOP_BUILDDIR
  48 CF_SUBST_NCURSES_VERSION
  49 CF_VERSION_INFO(NCURSES,ncurses)
  50
  51 CF_WITH_REL_VERSION(NCURSES)
  52 CF_NCURSES_WITH_ABI_VERSION
  53
  54 CF_WITH_SYSTYPE
  55
  56 ###     Save the given $CFLAGS to allow user-override.
  57 cf_user_CFLAGS="$CFLAGS"
  58
  59 ###     Default install-location
  60 CF_CFG_DEFAULTS
  61 ### Defaults for ncurses ABI
  62 CF_ABI_DEFAULTS
  63
  64 ### override ABI version, e.g., packagers
  65 CF_WITH_ABI_ALTERED
  66
  67 ###     Checks for programs.
  68 AC_ARG_WITH(ada,
  69         [  --without-ada           suppress check for Ada compiler, don't build demo],
  70         [cf_with_ada=$withval],
  71         [cf_with_ada=yes])
  72
  73 if test "x$cf_with_ada" = xyes
  74 then
  75         cf_prog_cc="gnatgcc gcc cc"
  76 else
  77         cf_prog_cc="gcc cc"
  78 fi
  79 CF_PROG_CC($cf_prog_cc)
  80
  81 AC_PROG_CPP
  82 AC_PROG_GCC_TRADITIONAL
  83 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
  84 CF_PROG_LDCONFIG
  85
  86 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  87 dnl                             configure script by not letting us test if C++
  88 dnl                             is present, making this option necessary.
  89 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  90 AC_ARG_WITH(cxx,
  91         [  --without-cxx           do not adjust ncurses bool to match C++],
  92         [cf_with_cxx=$withval],
  93         [cf_with_cxx=yes])
  94 AC_MSG_RESULT($cf_with_cxx)
  95 if test "X$cf_with_cxx" = Xno ; then
  96         CXX=""
  97         GXX=""
  98 else
  99         # with autoconf 2.13, we can change the error to a warning:
 100         pushdef([AC_MSG_ERROR],
 101                 [AC_MSG_RESULT(no)
 102                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
 103                 cf_with_cxx=no; CXX=""; GXX="";])dnl
 104         AC_PROG_CXX
 105         popdef([AC_MSG_ERROR])dnl
 106
 107         AC_LANG_PUSH(C++)
 108         if test "x$cf_with_cxx" != xno
 109         then
 110                 # Several of the C++ configurations do not work, particularly when
 111                 # cross-compiling (20140913 -TD)
 112                 AC_MSG_CHECKING(if $CXX works)
 113
 114                 save_CPPFLAGS="$CPPFLAGS"
 115                 eval cf_includedir=${includedir}
 116                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
 117                 AC_TRY_COMPILE([
 118 #include <stdlib.h>
 119 #include <stdio.h>
 120 ],
 121                 [
 122                 printf("Hello world!\n")
 123                 ],
 124                 [cf_cxx_works=yes],
 125                 [cf_cxx_works=no])
 126                 CPPFLAGS="$save_CPPFLAGS"
 127
 128                 AC_MSG_RESULT($cf_cxx_works)
 129                 if test "x$cf_cxx_works" = xno
 130                 then
 131                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
 132                         cf_with_cxx=no; CXX=""; GXX="";
 133                 fi
 134         fi
 135         AC_LANG_POP
 136
 137         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
 138         if test "$CXX" = "g++" ; then
 139                 AC_PATH_PROG(CXX,g++)
 140         fi
 141         case "x$CXX" in
 142         (x|xg++)
 143                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
 144                 cf_with_cxx=no; CXX=""; GXX="";
 145                 ;;
 146         esac
 147 fi
 148
 149 CF_GXX_VERSION
 150 case "$GXX_VERSION" in
 151 ([[1-9]][[0-9]].*)
 152         ;;
 153 (1.*|2.[[0-6]]*)
 154         AC_MSG_WARN(templates do not work)
 155         ;;
 156 esac
 157
 158 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 159 AC_ARG_WITH(cxx-binding,
 160         [  --without-cxx-binding   do not build C++ binding and demo],
 161         [cf_with_cxx_binding=$withval],
 162         [cf_with_cxx_binding=$cf_with_cxx])
 163 AC_MSG_RESULT($cf_with_cxx_binding)
 164
 165 AC_MSG_CHECKING(if you want to build with Ada)
 166 AC_MSG_RESULT($cf_with_ada)
 167
 168 AC_MSG_CHECKING(if you want to install terminal database)
 169 AC_ARG_ENABLE(db-install,
 170         [  --disable-db-install    suppress install of terminal database],
 171         [cf_with_db_install=$enableval],
 172         [cf_with_db_install=yes])
 173 AC_MSG_RESULT($cf_with_db_install)
 174
 175 AC_MSG_CHECKING(if you want to install manpages)
 176 AC_ARG_WITH(manpages,
 177         [  --without-manpages      suppress install of manpages],
 178         [cf_with_manpages=$withval],
 179         [cf_with_manpages=yes])
 180 AC_MSG_RESULT($cf_with_manpages)
 181
 182 AC_MSG_CHECKING(if you want to build programs such as tic)
 183 AC_ARG_WITH(progs,
 184         [  --without-progs         suppress build/install with programs (e.g., tic)],
 185         [cf_with_progs=$withval],
 186         [cf_with_progs=yes])
 187 AC_MSG_RESULT($cf_with_progs)
 188
 189 AC_MSG_CHECKING(if you want to build test-programs)
 190 AC_ARG_WITH(tests,
 191         [  --without-tests         suppress build/install with test-programs],
 192         [cf_with_tests=$withval],
 193         [cf_with_tests=yes])
 194 AC_MSG_RESULT($cf_with_tests)
 195
 196 AC_MSG_CHECKING(if you wish to install curses.h)
 197 AC_ARG_WITH(curses-h,
 198         [  --without-curses-h      install curses.h as ncurses.h only],
 199         [with_curses_h=$withval],
 200         [with_curses_h=yes])
 201 AC_MSG_RESULT($with_curses_h)
 202
 203 modules_to_build="ncurses"
 204 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
 205 modules_to_build="$modules_to_build panel menu form"
 206
 207 AC_ARG_PROGRAM
 208
 209 CF_PROG_AWK
 210 CF_PROG_INSTALL
 211 CF_PROG_LINT
 212 CF_PROG_LN_S
 213
 214 AC_SYS_LONG_FILE_NAMES
 215
 216 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
 217 # of package conflict.
 218 cf_config_suffix=
 219 AC_ARG_WITH(config-suffix,
 220         [  --with-config-suffix=X  name ncurses*X-config file with X],
 221         [case "x$withval" in
 222         (xyes|xno)
 223                 AC_MSG_WARN(expected a value for config-suffix option)
 224                 ;;
 225         (*)     cf_config_suffix="$withval"
 226                 ;;
 227         esac])
 228 AC_SUBST(cf_config_suffix)
 229
 230 # If we find pkg-config, check if we should install the ".pc" files.
 231 CF_PKG_CONFIG
 232 CF_WITH_PKG_CONFIG_LIBDIR
 233 CF_ENABLE_PC_FILES
 234 if test -z "$MAKE_PC_FILES"
 235 then
 236         AC_MSG_CHECKING(for suffix to add to pkg-config files)
 237 AC_ARG_WITH(pc-suffix,
 238         [[  --with-pc-suffix[=XXX]  suffix pkg-config files with XXX]],
 239         [case "x$withval" in
 240         (xyes|xno)
 241                 PC_MODULE_SUFFIX=
 242                 ;;
 243         (*)     PC_MODULE_SUFFIX="$withval"
 244                 ;;
 245         esac])
 246         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
 247         AC_MSG_RESULT($PC_MODULE_SUFFIX)
 248         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
 249         AC_SUBST(PC_MODULE_SUFFIX)
 250 fi
 251
 252 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 253 AC_ARG_ENABLE(mixed-case,
 254         [  --enable-mixed-case     tic should assume mixed-case filenames],
 255         [enable_mixedcase=$enableval],
 256         [enable_mixedcase=auto])
 257 AC_MSG_RESULT($enable_mixedcase)
 258 if test "$enable_mixedcase" = "auto" ; then
 259         CF_MIXEDCASE_FILENAMES
 260 else
 261         cf_cv_mixedcase=$enable_mixedcase
 262         if test "x$enable_mixedcase" = "xyes" ; then
 263                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
 264         fi
 265 fi
 266
 267 # do this after mixed-case option (tags/TAGS is not as important as tic).
 268 AC_PROG_MAKE_SET
 269 CF_MAKE_PHONY
 270 CF_MAKE_TAGS
 271 CF_MAKEFLAGS
 272
 273 dnl These are standard among *NIX systems, but not when cross-compiling
 274 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 275 AC_CHECK_TOOL(LD, ld, ld)
 276 AC_CHECK_TOOL(AR, ar, ar)
 277 AC_CHECK_TOOL(NM, nm, nm)
 278 CF_AR_FLAGS
 279
 280 dnl Special option for use by system-builders: the install-prefix is used to
 281 dnl adjust the location into which the actual install is done, so that an
 282 dnl archive can be built without modifying the host system's configuration.
 283 AC_MSG_CHECKING(for an installation directory prefix)
 284 AC_ARG_WITH(install-prefix,
 285         [  --with-install-prefix=DESTDIR use DESTDIR as installation directory prefix],
 286         [case "x$withval" in
 287         (xyes|xno)
 288                 ;;
 289         (*)     DESTDIR="$withval"
 290                 ;;
 291         esac])
 292 AC_MSG_RESULT([${DESTDIR:-(none)}])
 293 AC_SUBST(DESTDIR)
 294
 295 ###############################################################################
 296 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 297 # If we're cross-compiling, allow the user to override the tools and their
 298 # options.  The configure script is oriented toward identifying the host
 299 # compiler, etc., but we need a build compiler to generate parts of the source.
 300
 301 case "$cf_cv_system_name" in
 302 (*-msvc*)
 303         LDFLAGS="$LDFLAGS user32.lib"
 304         export LDFLAGS
 305         ;;
 306 esac
 307
 308 CF_BUILD_CC
 309
 310 ###############################################################################
 311 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 312
 313 ### Options to allow the user to specify the set of libraries which are used.
 314 ### Use "--without-normal --with-shared" to allow the default model to be
 315 ### shared, for example.
 316 cf_list_models=""
 317 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 318
 319 CF_WITH_LIBTOOL
 320 if test "$with_libtool" != "no" ; then
 321
 322 cf_list_models="$cf_list_models libtool"
 323
 324 else
 325
 326 AC_MSG_CHECKING(if you want to build shared libraries)
 327 AC_ARG_WITH(shared,
 328         [  --with-shared           generate shared-libraries],
 329         [with_shared=$withval],
 330         [with_shared=no])
 331 AC_MSG_RESULT($with_shared)
 332 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
 333
 334 AC_MSG_CHECKING(if you want to build static libraries)
 335 AC_ARG_WITH(normal,
 336         [  --with-normal           generate normal-libraries (default)],
 337         [with_normal=$withval],
 338         [with_normal=yes])
 339 AC_MSG_RESULT($with_normal)
 340 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
 341
 342 AC_MSG_CHECKING(if you want to build debug libraries)
 343 AC_ARG_WITH(debug,
 344         [  --with-debug            generate debug-libraries (default)],
 345         [with_debug=$withval],
 346         [with_debug=yes])
 347 AC_MSG_RESULT($with_debug)
 348 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
 349
 350 AC_MSG_CHECKING(if you want to build profiling libraries)
 351 AC_ARG_WITH(profile,
 352         [  --with-profile          generate profile-libraries],
 353         [with_profile=$withval],
 354         [with_profile=no])
 355 AC_MSG_RESULT($with_profile)
 356 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
 357
 358 fi
 359
 360 if test "X$cf_with_cxx_binding" != Xno; then
 361 if test "x$with_shared" = "xyes"; then
 362 AC_MSG_CHECKING(if you want to build C++ shared libraries)
 363 AC_ARG_WITH(cxx-shared,
 364         [  --with-cxx-shared       generate C++ shared-libraries],
 365         [with_shared_cxx=$withval],
 366         [with_shared_cxx=no])
 367 AC_MSG_RESULT($with_shared_cxx)
 368 fi
 369 fi
 370
 371 ###############################################################################
 372
 373 AC_MSG_CHECKING(for specified models)
 374 test -z "$cf_list_models" && cf_list_models=normal
 375 dnl If we use libtool to generate libraries, then it must be the only
 376 dnl specified model.
 377 test "$with_libtool" != "no" && cf_list_models=libtool
 378 AC_MSG_RESULT($cf_list_models)
 379
 380 ### Use the first model as the default, and save its suffix for use in building
 381 ### up test-applications.
 382 AC_MSG_CHECKING(for default model)
 383 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 384 AC_MSG_RESULT($DFT_LWR_MODEL)
 385
 386 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 387
 388 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 389 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 390
 391 TICS_NAME=tic
 392 AC_SUBST(TICS_NAME)
 393
 394 TINFO_NAME=tinfo
 395 AC_SUBST(TINFO_NAME)
 396
 397 LIB_NAME=ncurses
 398 AC_SUBST(LIB_NAME)
 399
 400 LIB_DIR=../lib
 401 LIB_2ND=../../lib
 402
 403 CF_WITH_LIB_PREFIX(cf_prefix)
 404
 405 LIB_SUFFIX=
 406 AC_SUBST(LIB_SUFFIX)
 407 CF_PATHSEP
 408
 409 # headers needed for checks...
 410 AC_CHECK_DECL(exit)
 411 AC_HEADER_DIRENT
 412
 413 ###############################################################################
 414
 415 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 416 AC_ARG_WITH(termlib,
 417         [  --with-termlib          generate separate terminfo library],
 418         [with_termlib=$withval],
 419         [with_termlib=no])
 420 AC_MSG_RESULT($with_termlib)
 421
 422 AC_MSG_CHECKING(if you want to build a separate tic library)
 423 AC_ARG_WITH(ticlib,
 424         [  --with-ticlib           generate separate tic library],
 425         [with_ticlib=$withval],
 426         [with_ticlib=no])
 427 AC_MSG_RESULT($with_ticlib)
 428
 429 dnl Not all ports of gcc support the -g option
 430
 431 if test X"$CC_G_OPT" = X"" ; then
 432         CC_G_OPT='-g'
 433         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
 434 fi
 435 AC_SUBST(CC_G_OPT)
 436
 437 if test X"$CXX_G_OPT" = X"" ; then
 438         CXX_G_OPT='-g'
 439         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
 440 fi
 441 AC_SUBST(CXX_G_OPT)
 442
 443 AC_MSG_CHECKING(for default loader flags)
 444 case "$DFT_LWR_MODEL" in
 445 (libtool) LD_MODEL=''   ;;
 446 (normal)  LD_MODEL=''   ;;
 447 (debug)   LD_MODEL=$CC_G_OPT ;;
 448 (profile) LD_MODEL='-pg';;
 449 (shared)  LD_MODEL=''   ;;
 450 esac
 451 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 452 AC_MSG_RESULT([${LD_MODEL:-(none)}])
 453
 454 case "$DFT_LWR_MODEL" in
 455 (shared)
 456 CF_ENABLE_RPATH
 457 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 458 AC_ARG_ENABLE(relink,
 459 [  --disable-relink        relink shared libraries during install],
 460 [cf_cv_do_relink=$enableval],
 461 [cf_cv_do_relink=yes])
 462 AC_MSG_RESULT($cf_cv_do_relink)
 463         ;;
 464 esac
 465
 466 # we will build libraries one-level down.
 467 rel_builddir=..
 468 CF_SHARED_OPTS
 469 for model in $cf_list_models ; do
 470         case "$model" in
 471         (libtool)
 472                 CF_WITH_LIBTOOL_OPTS
 473                 CF_WITH_EXPORT_SYMS
 474                 ;;
 475         (shared)
 476                 if test "$CC_SHARED_OPTS" = "unknown"; then
 477                         AC_ERROR(Shared libraries are not supported in this version)
 478                 fi
 479                 # workaround for inept transition to PIE vs PIC...
 480                 AC_MSG_CHECKING(if current CFLAGS link properly)
 481                 AC_TRY_LINK(
 482                         [#include <stdio.h>],
 483                         [printf("Hello work\\n");],
 484                         [cf_cflags_work=yes],
 485                         [cf_cflags_work=no])
 486                 AC_MSG_RESULT($cf_cflags_work)
 487                 if test "$cf_cflags_work" = no
 488                 then
 489                         CF_VERBOSE(try to work around by appending shared-options)
 490                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
 491                 fi
 492                 CF_WITH_VERSIONED_SYMS
 493                 ;;
 494         esac
 495 done
 496
 497 ### Checks for special libraries, must be done up-front.
 498 SHLIB_LIST=""
 499 CF_WITH_GPM
 500 if test "$with_gpm" != no ; then
 501         AC_MSG_CHECKING(if you want to load GPM dynamically)
 502         AC_ARG_WITH(dlsym,
 503                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 504                 [with_dlsym=$withval],
 505                 [with_dlsym=yes])
 506         AC_MSG_RESULT($with_dlsym)
 507         if test "x$with_dlsym" = xyes ; then
 508                 CF_FUNC_DLSYM
 509                 if test "x$with_gpm" != xyes ; then
 510                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 511                         cf_cv_gpm_soname="$with_gpm"
 512                 else
 513                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 514                 fi
 515                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
 516                 SHLIB_LIST="-ldl $SHLIB_LIST"
 517                 CF_ADD_LIB(dl,PRIVATE_LIBS)
 518         else
 519                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 520                 CF_ADD_LIB(gpm,TEST_LIBS)
 521                 CF_ADD_LIB(gpm,PRIVATE_LIBS)
 522         fi
 523         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
 524         CF_CHECK_GPM_WGETCH
 525 fi
 526
 527 CF_WITH_PCRE2
 528 CF_WITH_SYSMOUSE
 529
 530 # pretend that ncurses==ncursesw==ncursest
 531 AC_MSG_CHECKING(if you want to disable library suffixes)
 532 CF_ARG_DISABLE(lib-suffixes,
 533         [  --disable-lib-suffixes  disable library suffixes],
 534         [disable_lib_suffixes=yes],
 535         [disable_lib_suffixes=no],
 536         no)
 537 AC_MSG_RESULT($disable_lib_suffixes)
 538
 539 ### If we're building with rpath, try to link non-standard libs that way too.
 540 if test "$DFT_LWR_MODEL" = "shared" && test "x$cf_cv_enable_rpath" != xno; then
 541         CF_DISABLE_RPATH_HACK
 542 fi
 543
 544 ### Depending on the system, someone may use rpath to build ncurses but not
 545 # want users of the package to rely upon that feature.  Give those people an
 546 # option to suppress that detail from EXTRA_LDFLAGS.
 547 EXTRA_PKG_LDFLAGS="$LDFLAGS $EXTRA_LDFLAGS"
 548 if test -n "$EXTRA_PKG_LDFLAGS"
 549 then
 550         AC_MSG_CHECKING(if you want to disable extra LDFLAGS for package-scripts)
 551         CF_ARG_DISABLE(pkg-ldflags,
 552                 [  --disable-pkg-ldflags   disable extra LDFLAGS for package-scripts],
 553                 [disable_pkg_ldflags=yes],
 554                 [disable_pkg_ldflags=no],
 555                 no)
 556         AC_MSG_RESULT($disable_pkg_ldflags)
 557         test "$disable_pkg_ldflags" = yes && EXTRA_PKG_LDFLAGS=
 558 fi
 559 AC_SUBST(EXTRA_PKG_LDFLAGS)
 560
 561 ###############################################################################
 562 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 563
 564 ###     use option --with-extra-suffix to append suffix to headers and libraries
 565 AC_MSG_CHECKING(for extra suffix to append to header/library paths)
 566 EXTRA_SUFFIX=
 567 AC_ARG_WITH(extra-suffix,
 568         [[  --with-extra-suffix[=X] append extra suffix X to header/library paths]],
 569         [case x$withval in
 570         (xno)
 571                 ;;
 572         (xyes|x)
 573                 EXTRA_SUFFIX=$cf_cv_abi_version
 574                 ;;
 575         (*)
 576                 EXTRA_SUFFIX=$withval
 577                 ;;
 578         esac
 579         ])
 580 AC_MSG_RESULT([${EXTRA_SUFFIX:-(none)}])
 581 AC_SUBST(EXTRA_SUFFIX)
 582
 583 ###     use option --disable-overwrite to leave out the link to -lcurses
 584 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 585 AC_ARG_ENABLE(overwrite,
 586         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
 587         [with_overwrite=$enableval],
 588         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 589 AC_MSG_RESULT($with_overwrite)
 590
 591 AC_MSG_CHECKING(if external terminfo-database is used)
 592 AC_ARG_ENABLE(database,
 593         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 594         [use_database=$enableval],
 595         [use_database=yes])
 596 AC_MSG_RESULT($use_database)
 597
 598 case "$host_os" in
 599 (os2*)
 600         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 601         ;;
 602 (*)
 603         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 604         ;;
 605 esac
 606 AC_SUBST(TERMINFO_SRC)
 607
 608 NCURSES_USE_DATABASE=0
 609 if test "$use_database" != no ; then
 610         NCURSES_USE_DATABASE=1
 611
 612         AC_MSG_CHECKING(which terminfo source-file will be installed)
 613         AC_ARG_WITH(database,
 614                 [  --with-database=XXX     specify terminfo source to install],
 615                 [TERMINFO_SRC=$withval])
 616         AC_MSG_RESULT($TERMINFO_SRC)
 617
 618         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 619         AC_ARG_WITH(hashed-db,
 620                 [  --with-hashed-db        specify hashed-database library],,
 621                 [with_hashed_db=no])
 622         AC_MSG_RESULT($with_hashed_db)
 623 else
 624         with_hashed_db=no
 625 fi
 626 AC_SUBST(NCURSES_USE_DATABASE)
 627
 628 AC_MSG_CHECKING(for list of fallback terminal descriptions)
 629 AC_ARG_WITH(fallbacks,
 630         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 631         [with_fallback=$withval],
 632         [with_fallback=])
 633 AC_MSG_RESULT([${with_fallback:-(none)}])
 634
 635 case ".$with_fallback" in
 636 (.|.no)
 637         FALLBACK_LIST=
 638         ;;
 639 (.yes)
 640         AC_MSG_WARN(expected a list of terminal descriptions)
 641         ;;
 642 (*)
 643         FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 644         ;;
 645 esac
 646
 647 # The fallback feature in ncurses relies upon tic/infocmp outside the build
 648 # tree for generating the terminal descriptions that will be compiled into the
 649 # library.  If your toolchain is old, it may not handle current terminal
 650 # databases.  Use configure-options to point to the tools which will be used,
 651 # rather than the first ones found on the $PATH.
 652 AC_CHECK_TOOL(TIC, tic)
 653 AC_CHECK_TOOL(INFOCMP, infocmp)
 654 if test -n "$FALLBACK_LIST"
 655 then
 656         CF_WITH_PATH_PROG(TIC,     tic,     [for fallbacks], $PATH:/usr/local/ncurses/bin)
 657         CF_WITH_PATH_PROG(INFOCMP, infocmp, [for fallbacks], $PATH:/usr/local/ncurses/bin)
 658         test -z "$TIC" && FALLBACK_LIST=
 659         test -z "$INFOCMP" && FALLBACK_LIST=
 660         if test -z "$FALLBACK_LIST"
 661         then
 662                 AC_MSG_WARN(ignoring fallback option because tic/infocmp are not available)
 663         fi
 664 fi
 665 AC_SUBST(TIC)
 666 AC_SUBST(INFOCMP)
 667
 668 USE_FALLBACKS=
 669 test -z "$FALLBACK_LIST" && USE_FALLBACKS="#"
 670 AC_SUBST(FALLBACK_LIST)
 671 AC_SUBST(USE_FALLBACKS)
 672
 673 AC_MSG_CHECKING(if you want modern xterm or antique)
 674 AC_ARG_WITH(xterm-new,
 675         [  --without-xterm-new     specify if xterm terminfo should be old version],
 676         [with_xterm_new=$withval],
 677         [with_xterm_new=yes])
 678 case "$with_xterm_new" in
 679 (no) with_xterm_new=xterm-old;;
 680 (*)      with_xterm_new=xterm-new;;
 681 esac
 682 AC_MSG_RESULT($with_xterm_new)
 683 WHICH_XTERM=$with_xterm_new
 684 AC_SUBST(WHICH_XTERM)
 685
 686 case $host_os in
 687 (*linux-gnu|*cygwin|*mingw32|*msys)
 688         want_xterm_kbs=DEL
 689         ;;
 690 (*)
 691         want_xterm_kbs=BS
 692         ;;
 693 esac
 694
 695 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 696 AC_ARG_WITH(xterm-kbs,
 697         [[  --with-xterm-kbs[=XXX]  specify if xterm backspace sends BS or DEL]],
 698         [with_xterm_kbs=$withval],
 699         [with_xterm_kbs=auto])
 700 case x$with_xterm_kbs in
 701 (xyes|xno|xBS|xbs|x8)
 702         with_xterm_kbs=BS
 703         ;;
 704 (xDEL|xdel|x127)
 705         with_xterm_kbs=DEL
 706         ;;
 707 (xauto)
 708         with_xterm_kbs=$want_xterm_kbs
 709         ;;
 710 (*)
 711         with_xterm_kbs=$withval
 712         ;;
 713 esac
 714 AC_MSG_RESULT($with_xterm_kbs)
 715 XTERM_KBS=$with_xterm_kbs
 716 AC_SUBST(XTERM_KBS)
 717
 718 if test "x$with_xterm_kbs" != "x$want_xterm_kbs"
 719 then
 720         AC_MSG_WARN([expected --with-xterm-kbs=$want_xterm_kbs for $host_os, have $with_xterm_kbs])
 721 fi
 722
 723 MAKE_TERMINFO=
 724 if test "$use_database" = no ; then
 725         TERMINFO="${datadir}/terminfo"
 726         MAKE_TERMINFO="#"
 727 else
 728
 729 AC_MSG_CHECKING(for list of terminfo directories)
 730 CF_WITH_PATHLIST(terminfo-dirs,
 731         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 732         TERMINFO_DIRS,
 733         DATADIR/terminfo,
 734         ${datadir}/terminfo)
 735 AC_MSG_RESULT($TERMINFO_DIRS)
 736 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
 737
 738 case "x$TERMINFO" in
 739 x???:*)
 740         AC_MSG_WARN(ignoring non-directory/file TERMINFO value)
 741         unset TERMINFO
 742         ;;
 743 esac
 744
 745 AC_MSG_CHECKING(for default terminfo directory)
 746 CF_WITH_PATH(default-terminfo-dir,
 747         [  --with-default-terminfo-dir=DIR default terminfo directory],
 748         TERMINFO,
 749         DATADIR/terminfo,
 750         ${datadir}/terminfo)
 751 AC_MSG_RESULT($TERMINFO)
 752 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
 753
 754 fi
 755
 756 AC_SUBST(TERMINFO)
 757 AC_SUBST(MAKE_TERMINFO)
 758
 759 ###     use option --disable-big-core to make tic run on small machines
 760 ###     We need 4Mb, check if we can allocate 50% more than that.
 761 AC_MSG_CHECKING(if big-core option selected)
 762 AC_ARG_ENABLE(big-core,
 763         [  --disable-big-core      assume machine has little memory],
 764         [with_big_core=$enableval],
 765         [AC_TRY_RUN([
 766 #include <stdlib.h>
 767 #include <string.h>
 768 int main(void) {
 769         unsigned long n = 6000000L;
 770         char *s = malloc(n);
 771         if (s != 0)
 772                 s[0] = s[n-1] = 0;
 773         ${cf_cv_main_return:-return}(s == 0);
 774 }],
 775         [with_big_core=yes],
 776         [with_big_core=no],
 777         [with_big_core=no])])
 778 AC_MSG_RESULT($with_big_core)
 779 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
 780
 781 ### ISO C only guarantees 512-char strings, we have tables which load faster
 782 ### when constructed using "big" strings.  More than the C compiler, the awk
 783 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 784 AC_MSG_CHECKING(if big-strings option selected)
 785 AC_ARG_ENABLE(big-strings,
 786         [  --disable-big-strings   assume compiler has only standard-size strings],
 787         [with_big_strings=$enableval],
 788         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 789 AC_MSG_RESULT($with_big_strings)
 790
 791 USE_BIG_STRINGS=0
 792 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
 793 AC_SUBST(USE_BIG_STRINGS)
 794
 795 ###     use option --enable-termcap to compile in the termcap fallback support
 796 AC_MSG_CHECKING(if you want termcap-fallback support)
 797 AC_ARG_ENABLE(termcap,
 798         [  --enable-termcap        compile in termcap fallback support],
 799         [with_termcap=$enableval],
 800         [with_termcap=no])
 801 AC_MSG_RESULT($with_termcap)
 802
 803 NCURSES_USE_TERMCAP=0
 804 if test "x$with_termcap" != "xyes" ; then
 805         if test "$use_database" = no ; then
 806                 if test -z "$with_fallback" ; then
 807                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 808                 fi
 809         fi
 810         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
 811 else
 812
 813         if test "$with_ticlib" != no ; then
 814                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 815         fi
 816
 817         NCURSES_USE_TERMCAP=1
 818         AC_MSG_CHECKING(for list of termcap files)
 819         CF_WITH_PATHLIST(termpath,
 820                 [  --with-termpath=XXX     specify list of termcap files],
 821                 TERMPATH,
 822                 /etc/termcap:/usr/share/misc/termcap)
 823         AC_MSG_RESULT($TERMPATH)
 824         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
 825
 826         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 827         AC_MSG_CHECKING(if fast termcap-loader is needed)
 828         AC_ARG_ENABLE(getcap,
 829                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 830                 [with_getcap=$enableval],
 831                 [with_getcap=no])
 832         AC_MSG_RESULT($with_getcap)
 833         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
 834
 835         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 836         AC_ARG_ENABLE(getcap-cache,
 837                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 838                 [with_getcap_cache=$enableval],
 839                 [with_getcap_cache=no])
 840         AC_MSG_RESULT($with_getcap_cache)
 841         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
 842
 843 fi
 844 AC_SUBST(NCURSES_USE_TERMCAP)
 845
 846 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 847 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 848 AC_ARG_ENABLE(home-terminfo,
 849         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 850         [with_home_terminfo=$enableval],
 851         [with_home_terminfo=yes])
 852 AC_MSG_RESULT($with_home_terminfo)
 853 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
 854
 855 AC_MSG_CHECKING(if you want to permit root to use ncurses environment variables)
 856 AC_ARG_ENABLE(root-environ,
 857         [  --disable-root-environ  restrict root use of ncurses environment variables],
 858         [with_root_environ=$enableval],
 859         [with_root_environ=yes])
 860 AC_MSG_RESULT($with_root_environ)
 861 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if root/setuid application is allowed to use ncurses environment])
 862
 863 AC_MSG_CHECKING(if you want to permit setuid programs to access all files)
 864 AC_ARG_ENABLE(root-access,
 865         [  --disable-root-access   restrict file-access when running setuid],
 866         [with_root_access=$enableval],
 867         [with_root_access=yes])
 868 AC_MSG_RESULT($with_root_access)
 869 test "x$with_root_access" = xyes && AC_DEFINE(USE_ROOT_ACCESS,1,[Define to 1 if setuid is allowed all file-access])
 870
 871 AC_MSG_CHECKING(if you want to permit setuid use of ncurses environment variables)
 872 AC_ARG_ENABLE(setuid-environ,
 873         [  --disable-setuid-environ restrict setuid use of ncurses environment variables],
 874         [with_setuid_environ=$enableval],
 875         [with_setuid_environ=$with_root_environ])
 876 AC_MSG_RESULT($with_setuid_environ)
 877 test "x$with_setuid_environ" = xyes && AC_DEFINE(USE_SETUID_ENVIRON,1,[Define to 1 if setuid/setgid application is allowed to use ncurses environment])
 878
 879 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 880 ###   to reduce storage requirements for the terminfo database.
 881 CF_LINK_FUNCS
 882
 883 with_links=no
 884 with_symlinks=no
 885
 886 # soft links (symbolic links) are useful for some systems where hard links do
 887 # not work, or to make it simpler to copy terminfo trees around.
 888 if test "x$ac_cv_func_symlink" = xyes ; then
 889         AC_MSG_CHECKING(if tic should use symbolic links)
 890         AC_ARG_ENABLE(symlinks,
 891         [  --enable-symlinks       make tic use symbolic links not hard links],
 892         [with_symlinks=$enableval],
 893         [with_symlinks=no])
 894         AC_MSG_RESULT($with_symlinks)
 895 fi
 896
 897 # If we have hard links and did not choose to use soft links instead, there is
 898 # no reason to make this choice optional - use the hard links.
 899 if test "$with_symlinks" = no ; then
 900         AC_MSG_CHECKING(if tic should use hard links)
 901         if test "x$ac_cv_func_link" = xyes ; then
 902                 with_links=yes
 903         else
 904                 with_links=no
 905         fi
 906         AC_MSG_RESULT($with_links)
 907 fi
 908
 909 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
 910 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
 911
 912 ###   use option --enable-broken-linker to force on use of broken-linker support
 913 CF_ENABLE_BROKEN_LINKER
 914
 915 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 916 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 917 AC_ARG_ENABLE(bsdpad,
 918         [  --enable-bsdpad         recognize BSD-style prefix padding],
 919         [with_bsdpad=$enableval],
 920         [with_bsdpad=no])
 921 AC_MSG_RESULT($with_bsdpad)
 922 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
 923
 924 ###   use option --enable-widec to turn on use of wide-character support
 925 NCURSES_CH_T=chtype
 926 NCURSES_LIBUTF8=0
 927
 928 NEED_WCHAR_H=0
 929 NCURSES_MBSTATE_T=0
 930 NCURSES_WCHAR_T=0
 931 NCURSES_WINT_T=0
 932
 933 # Check to define _XOPEN_SOURCE "automatically"
 934 CPPFLAGS_before_XOPEN="$CPPFLAGS"
 935 CF_XOPEN_SOURCE(600)
 936 CPPFLAGS_after_XOPEN="$CPPFLAGS"
 937
 938 # Work around breakage on OS X
 939 CF_SIGWINCH
 940
 941 # Checks for CODESET support.
 942 AM_LANGINFO_CODESET
 943
 944 # use these variables to work around a defect in gcc's fixincludes.
 945 NCURSES_OK_WCHAR_T=
 946 NCURSES_OK_WINT_T=
 947
 948 AC_MSG_CHECKING(if you want wide-character code)
 949 AC_ARG_ENABLE(widec,
 950         [  --disable-widec         compile without wide character and UTF-8 support],
 951         [with_widec=$enableval],
 952         [with_widec=$cf_dft_widec])
 953 AC_MSG_RESULT($with_widec)
 954
 955 NCURSES_WCWIDTH_GRAPHICS=1
 956 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
 957
 958 if test "x$with_widec" = xyes ; then
 959         if test "x$disable_lib_suffixes" = xno ; then
 960                 LIB_SUFFIX="w${LIB_SUFFIX}"
 961         fi
 962         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide character and UTF-8 support])
 963         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide character and UTF-8 support])
 964         case "$CPPFLAGS" in
 965         (*_XOPEN_SOURCE=*)
 966                 ;;
 967         (*)
 968                 AC_MSG_WARN(_XOPEN_SOURCE feature test macro appears to be predefined)
 969                 # CPPFLAGS="$CPPFLAGS -DNCURSES_WIDECHAR"
 970                 CPPFLAGS_after_XOPEN="$CPPFLAGS_after_XOPEN -DNCURSES_WIDECHAR"
 971                 ;;
 972         esac
 973
 974         CF_CHECK_WCHAR_H
 975         CF_CHECK_WCWIDTH_GRAPHICS
 976         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
 977
 978         # with_overwrite=no
 979         NCURSES_CH_T=cchar_t
 980         AC_CHECK_FUNCS(putwc btowc wctob wmemchr mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 981         if test "x$ac_cv_func_putwc" != xyes ; then
 982                 CF_UTF8_LIB
 983                 if test "$cf_cv_utf8_lib" != no ; then
 984                         NCURSES_LIBUTF8=1
 985                 fi
 986         fi
 987         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 988         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 989         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 990
 991         if test "$NCURSES_MBSTATE_T" != 0; then
 992                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
 993         fi
 994 fi
 995 AC_SUBST(NCURSES_CH_T)
 996 AC_SUBST(NCURSES_LIBUTF8)
 997
 998 AC_SUBST(NEED_WCHAR_H)
 999 AC_SUBST(NCURSES_MBSTATE_T)
1000 AC_SUBST(NCURSES_WCHAR_T)
1001 AC_SUBST(NCURSES_WINT_T)
1002
1003 AC_SUBST(NCURSES_OK_WCHAR_T)
1004 AC_SUBST(NCURSES_OK_WINT_T)
1005
1006 ###   use option --disable-lp64 to allow long chtype
1007 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
1008 AC_ARG_ENABLE(lp64,
1009         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
1010         [with_lp64=$enableval],
1011         [with_lp64=$cf_dft_with_lp64])
1012 AC_MSG_RESULT($with_lp64)
1013
1014 if test "x$with_lp64" = xyes ; then
1015         cf_cv_enable_lp64=1
1016 else
1017         cf_cv_enable_lp64=0
1018 fi
1019 AC_SUBST(cf_cv_enable_lp64)
1020
1021 CF_LARGEFILE
1022
1023 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
1024 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
1025 AC_ARG_ENABLE(tparm-varargs,
1026         [  --disable-tparm-varargs compile tparm() without varargs interface],
1027         [with_tparm_varargs=$enableval],
1028         [with_tparm_varargs=yes])
1029 AC_MSG_RESULT($with_tparm_varargs)
1030 NCURSES_TPARM_VARARGS=0
1031 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
1032 AC_SUBST(NCURSES_TPARM_VARARGS)
1033
1034 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
1035 if test "$with_ticlib" != no ; then
1036 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
1037 AC_ARG_ENABLE(tic-depends,
1038         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
1039         [with_tic_depends=$enableval],
1040         [with_tic_depends=yes])
1041 AC_MSG_RESULT($with_tic_depends)
1042 else
1043         with_tic_depends=no
1044 fi
1045
1046 ###   use option --enable-wattr-macros to enable wattr* macros in curses.h
1047 AC_MSG_CHECKING(if you want to enable wattr* macros)
1048 AC_ARG_ENABLE(wattr-macros,
1049         [  --enable-wattr-macros   enable wattr* macros],
1050         [with_wattr_macros=$enableval],
1051         [with_wattr_macros=no])
1052 if [[ "x$with_wattr_macros" != xyes ]]; then
1053         NCURSES_WATTR_MACROS=0
1054         AC_MSG_RESULT(no)
1055 else
1056         NCURSES_WATTR_MACROS=1
1057         AC_MSG_RESULT(yes)
1058 fi
1059 AC_SUBST(NCURSES_WATTR_MACROS)
1060
1061 CF_WITH_X11_RGB
1062
1063 ###   use option --with-bool to override bool's type
1064 CF_WITH_TYPE(bool,
1065         [  --with-bool=TYPE        fall back to TYPE for curses 'bool' typedef],
1066         NCURSES_BOOL,
1067         auto)
1068
1069 AC_MSG_CHECKING(for alternate terminal capabilities file)
1070 AC_ARG_WITH(caps,
1071         [  --with-caps=alt         compile with alternate Caps file],
1072         [TERMINFO_CAPS=Caps.$withval],
1073         [TERMINFO_CAPS=Caps])
1074 if test ! -f "${srcdir}/include/${TERMINFO_CAPS}"
1075 then
1076         AC_MSG_WARN(file not found: "${srcdir}/include/${TERMINFO_CAPS}")
1077         TERMINFO_CAPS=Caps
1078 fi
1079 AC_MSG_RESULT($TERMINFO_CAPS)
1080 AC_SUBST(TERMINFO_CAPS)
1081
1082 ###   use option --with-chtype to override chtype's type
1083 CF_WITH_TYPE(chtype,
1084         [  --with-chtype=TYPE      override type of chtype],
1085         NCURSES_CHTYPE,
1086         $cf_dft_chtype)
1087
1088 ###   use option --with-ospeed to override ospeed's type
1089 CF_WITH_TYPE(ospeed,
1090         [  --with-ospeed=TYPE      override type of ospeed variable],
1091         NCURSES_OSPEED,
1092         short)
1093
1094 ###   use option --with-mmask-t to override mmask_t's type
1095 CF_WITH_TYPE(mmask-t,
1096         [  --with-mmask-t=TYPE     override type of mmask_t],
1097         NCURSES_MMASK_T,
1098         $cf_dft_mmask_t)
1099
1100 ###   use option --with-ccharw-max to override CCHARW_MAX size
1101 AC_MSG_CHECKING(for size CCHARW_MAX)
1102 AC_ARG_WITH(ccharw-max,
1103         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1104         [NCURSES_CCHARW_MAX="$withval"],
1105         [NCURSES_CCHARW_MAX=$cf_dft_ccharw_max])
1106 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1107 AC_SUBST(NCURSES_CCHARW_MAX)
1108
1109 AC_CHECK_SIZEOF([signed char])
1110 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1111         NCURSES_SBOOL="signed char"
1112 else
1113         NCURSES_SBOOL="char"
1114 fi
1115 AC_MSG_CHECKING(whether to use signed chars for Boolean array in term.h)
1116 AC_ARG_ENABLE(signed-char,
1117         [  --enable-signed-char    use signed chars for Boolean array in term.h],
1118         [with_signed_char=$enableval],
1119         [with_signed_char=$cf_dft_signed_char])
1120 AC_MSG_RESULT($with_signed_char)
1121 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1122 AC_SUBST(NCURSES_SBOOL)
1123
1124 ###   use option --with-tparm-arg to override tparm's argument type
1125 CF_WITH_TYPE(tparm-arg,
1126         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1127         NCURSES_TPARM_ARG,
1128         $cf_dft_tparm_arg)
1129
1130 ### Enable compiling-in rcs id's
1131 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1132 AC_ARG_WITH(rcs-ids,
1133         [  --with-rcs-ids          compile-in RCS identifiers],
1134         [with_rcs_ids=$withval],
1135         [with_rcs_ids=no])
1136 AC_MSG_RESULT($with_rcs_ids)
1137 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1138
1139 ###############################################################################
1140 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1141
1142 ###############################################################################
1143 CF_HELP_MESSAGE(Extensions:)
1144
1145 ### Note that some functions (such as const) are normally disabled anyway.
1146 AC_MSG_CHECKING(if you want to build with function extensions)
1147 AC_ARG_ENABLE(ext-funcs,
1148         [  --disable-ext-funcs     disable function-extensions],
1149         [with_ext_funcs=$enableval],
1150         [with_ext_funcs=yes])
1151 AC_MSG_RESULT($with_ext_funcs)
1152 if test "x$with_ext_funcs" = xyes ; then
1153         NCURSES_EXT_FUNCS=1
1154         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1155         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1156         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1157         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1158         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1159         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1160         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1161         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1162         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1163         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1164         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1165         GENERATED_EXT_FUNCS=generated
1166         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1167 else
1168         NCURSES_EXT_FUNCS=0
1169         GENERATED_EXT_FUNCS=
1170 fi
1171 AC_SUBST(NCURSES_EXT_FUNCS)
1172 AC_SUBST(GENERATED_EXT_FUNCS)
1173
1174 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1175 AC_ARG_ENABLE(sp-funcs,
1176         [  --enable-sp-funcs       enable SCREEN-extensions],
1177         [with_sp_funcs=$enableval],
1178         [with_sp_funcs=$cf_dft_ext_spfuncs])
1179 AC_MSG_RESULT($with_sp_funcs)
1180 if test "x$with_sp_funcs" = xyes ; then
1181         NCURSES_SP_FUNCS=1
1182         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1183         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1184         GENERATED_SP_FUNCS=generated
1185 else
1186         NCURSES_SP_FUNCS=0
1187         GENERATED_SP_FUNCS=
1188 fi
1189 AC_SUBST(NCURSES_SP_FUNCS)
1190 AC_SUBST(GENERATED_SP_FUNCS)
1191
1192 AC_MSG_CHECKING(if you want to build with terminal-driver)
1193 AC_ARG_ENABLE(term-driver,
1194         [  --enable-term-driver    enable terminal-driver],
1195         [with_term_driver=$enableval],
1196         [with_term_driver=no])
1197 AC_MSG_RESULT($with_term_driver)
1198 if test "x$with_term_driver" = xyes ; then
1199         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1200         if test "x$with_termlib" != xno ; then
1201                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1202         fi
1203         if test "x$with_sp_funcs" != xyes ; then
1204                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1205         fi
1206 fi
1207
1208 ###   use option --enable-const to turn on use of const beyond that in XSI.
1209 AC_MSG_CHECKING(for extended use of const keyword)
1210 AC_ARG_ENABLE(const,
1211         [  --enable-const          compile with extra/non-standard const],
1212         [with_ext_const=$enableval],
1213         [with_ext_const=$cf_dft_ext_const])
1214 AC_MSG_RESULT($with_ext_const)
1215 NCURSES_CONST='/*nothing*/'
1216 if test "x$with_ext_const" = xyes ; then
1217         NCURSES_CONST=const
1218 fi
1219 AC_SUBST(NCURSES_CONST)
1220
1221 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1222 AC_MSG_CHECKING(if you want to use extended colors)
1223 AC_ARG_ENABLE(ext-colors,
1224         [  --enable-ext-colors     compile for 256-color support],
1225         [with_ext_colors=$enableval],
1226         [with_ext_colors=$cf_dft_ext_colors])
1227 AC_MSG_RESULT($with_ext_colors)
1228 NCURSES_EXT_COLORS=0
1229 if test "x$with_ext_colors" = xyes ; then
1230         if test "x$with_widec" != xyes ; then
1231                 AC_MSG_WARN(This option applies only to wide-character library)
1232         else
1233                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1234                 CF_NCURSES_ABI_6
1235                 NCURSES_EXT_COLORS=1
1236                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1237                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1238                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1239                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1240         fi
1241 fi
1242 AC_SUBST(NCURSES_EXT_COLORS)
1243
1244 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1245 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1246 AC_ARG_ENABLE(ext-mouse,
1247         [  --enable-ext-mouse      compile for extended mouse-encoding],
1248         [with_ext_mouse=$enableval],
1249         [with_ext_mouse=$cf_dft_ext_mouse])
1250 AC_MSG_RESULT($with_ext_mouse)
1251 if test "x$with_ext_mouse" = xyes ; then
1252         CF_NCURSES_ABI_6
1253 fi
1254
1255 if test $cf_cv_abi_default -le 5 ; then
1256         NCURSES_MOUSE_VERSION=1
1257 elif test $cf_cv_abi_default -le 6 ; then
1258         NCURSES_MOUSE_VERSION=2
1259 else
1260         NCURSES_MOUSE_VERSION=3
1261 fi
1262
1263 AC_SUBST(NCURSES_MOUSE_VERSION)
1264
1265 ###   use option --enable-ext-putwin to turn on extended screendumps
1266 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1267 AC_ARG_ENABLE(ext-putwin,
1268         [  --enable-ext-putwin     compile with extended putwin/screendump],
1269         [with_ext_putwin=$enableval],
1270         [with_ext_putwin=$cf_dft_ext_putwin])
1271 AC_MSG_RESULT($with_ext_putwin)
1272 if test "x$with_ext_putwin" = xyes ; then
1273         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1274 fi
1275
1276 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1277 AC_ARG_ENABLE(no-padding,
1278         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1279         [with_no_padding=$enableval],
1280         [with_no_padding=$with_ext_funcs])
1281 AC_MSG_RESULT($with_no_padding)
1282 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1283
1284 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1285 AC_MSG_CHECKING(if you want SIGWINCH handler)
1286 AC_ARG_ENABLE(sigwinch,
1287         [  --enable-sigwinch       compile with SIGWINCH handler],
1288         [with_sigwinch=$enableval],
1289         [with_sigwinch=$with_ext_funcs])
1290 AC_MSG_RESULT($with_sigwinch)
1291 if test "x$with_sigwinch" = xyes
1292 then
1293         AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1294         cf_cv_enable_sigwinch=1
1295 else
1296         cf_cv_enable_sigwinch=0
1297 fi
1298 AC_SUBST(cf_cv_enable_sigwinch)
1299
1300 ###   use option --enable-tcap-names to allow user to define new capabilities
1301 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1302 AC_ARG_ENABLE(tcap-names,
1303         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1304         [with_tcap_names=$enableval],
1305         [with_tcap_names=$with_ext_funcs])
1306 AC_MSG_RESULT($with_tcap_names)
1307 NCURSES_XNAMES=0
1308 if test "x$with_tcap_names" = xyes; then
1309         NCURSES_XNAMES=1
1310         AC_DEFINE(NCURSES_XNAMES,1,[Define to 1 to compile with user-definable terminal capabilities])
1311 fi
1312 AC_SUBST(NCURSES_XNAMES)
1313
1314 ##############################################################################
1315 CF_HELP_MESSAGE(Reentrant Code:)
1316 CF_WITH_PTHREAD
1317
1318 if test "x$with_pthread" != xno; then
1319         AC_CHECK_FUNC(pthread_kill,[
1320                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1321                 AC_ARG_ENABLE(pthreads-eintr,
1322                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1323                         [use_pthreads_eintr=$enableval],
1324                         [use_pthreads_eintr=no])
1325                 AC_MSG_RESULT($use_pthreads_eintr)
1326                 if test "x$use_pthreads_eintr" = xyes ; then
1327                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1328                 fi])
1329
1330         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1331         AC_ARG_ENABLE(weak-symbols,
1332                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1333                 [use_weak_symbols=$enableval],
1334                 [use_weak_symbols=no])
1335         AC_MSG_RESULT($use_weak_symbols)
1336         if test "x$use_weak_symbols" = xyes ; then
1337                 CF_WEAK_SYMBOLS
1338         else
1339                 cf_cv_weak_symbols=no
1340         fi
1341
1342         if test "x$cf_cv_weak_symbols" = xyes ; then
1343                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1344         fi
1345 fi
1346
1347 PTHREAD=
1348 if test "x$with_pthread" = "xyes" ; then
1349         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1350         enable_reentrant=yes
1351         if test "x$cf_cv_weak_symbols" = xyes ; then
1352                 PTHREAD=-lpthread
1353                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1354         fi
1355 fi
1356 AC_SUBST(PTHREAD)
1357
1358 # Reentrant code has to be opaque; there's little advantage to making ncurses
1359 # opaque outside of that, so there is no --enable-opaque option.  We can use
1360 # this option without --with-pthreads, but this will be always set for
1361 # pthreads.
1362 AC_MSG_CHECKING(if you want reentrant code)
1363 AC_ARG_ENABLE(reentrant,
1364         [  --enable-reentrant      compile with reentrant code],
1365         [with_reentrant=$enableval],
1366         [with_reentrant=no])
1367 AC_MSG_RESULT($with_reentrant)
1368 if test "x$with_reentrant" = xyes ; then
1369         cf_cv_enable_reentrant=1
1370         cf_cv_enable_opaque="NCURSES_INTERNALS"
1371         NCURSES_SIZE_T=int
1372         if test "x$cf_cv_weak_symbols" = xyes ; then
1373                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1374                 CF_ADD_LIB(pthread,TEST_LIBS)
1375                 CF_ADD_LIB(pthread,TEST_LIBS2)
1376                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1377         else
1378                 # when not using weak symbols but with_reentrant,
1379                 # add 't' to the library suffix on all platforms
1380                 # except cygwin, where we only do that if ALSO
1381                 # compiling with full thread support.
1382                 case "$host" in
1383                 (*cygwin* | *msys*)
1384                         if test "$with_pthread" = "yes" ; then
1385                                 if test "x$disable_lib_suffixes" = "xno" ; then
1386                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1387                                 fi
1388                         fi ;;
1389                 (*)
1390                         if test "x$disable_lib_suffixes" = "xno" ; then
1391                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1392                         fi
1393                         ;;
1394                 esac
1395         fi
1396         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1397         CF_NCURSES_ABI_6
1398 else
1399         cf_cv_enable_reentrant=0
1400         cf_cv_enable_opaque="NCURSES_OPAQUE"
1401         NCURSES_SIZE_T=$cf_dft_ordinate_type
1402 fi
1403 AC_SUBST(cf_cv_enable_reentrant)
1404 AC_SUBST(cf_cv_enable_opaque)
1405
1406 AC_SUBST(NCURSES_SIZE_T)
1407
1408 AC_MSG_CHECKING(whether curses library structures should be opaque)
1409 CF_ARG_ENABLE(opaque-curses,
1410         [  --disable-opaque-curses do not make WINDOW, etc., structures opaque],
1411         [enable_opaque_curses=yes],[
1412          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1413          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=$cf_dft_opaque_curses
1414         ])
1415 AC_MSG_RESULT($enable_opaque_curses)
1416
1417 test "$cf_cv_enable_reentrant" = 1 && \
1418 test "$enable_opaque_curses" = no && \
1419 AC_MSG_ERROR(reentrant configuration requires opaque library)
1420
1421 AC_MSG_CHECKING(whether form library structures should be opaque)
1422 AC_ARG_ENABLE(opaque-form,
1423         [  --disable-opaque-form   do not make form library structures opaque],
1424         [enable_opaque_form=yes],[enable_opaque_form=$cf_dft_opaque_curses])
1425 AC_MSG_RESULT($enable_opaque_form)
1426
1427 AC_MSG_CHECKING(whether menu library structures should be opaque)
1428 AC_ARG_ENABLE(opaque-menu,
1429         [  --disable-opaque-menu   do not make menu library structures opaque],
1430         [enable_opaque_menu=yes],[enable_opaque_menu=$cf_dft_opaque_curses])
1431 AC_MSG_RESULT($enable_opaque_menu)
1432
1433 AC_MSG_CHECKING(whether panel library structures should be opaque)
1434 AC_ARG_ENABLE(opaque-panel,
1435         [  --disable-opaque-panel  do not make panel library structures opaque],
1436         [enable_opaque_panel=yes],[enable_opaque_panel=$cf_dft_opaque_curses])
1437 AC_MSG_RESULT($enable_opaque_panel)
1438
1439 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1440 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1441 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1442 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1443
1444 AC_SUBST(NCURSES_OPAQUE)
1445 AC_SUBST(NCURSES_OPAQUE_FORM)
1446 AC_SUBST(NCURSES_OPAQUE_MENU)
1447 AC_SUBST(NCURSES_OPAQUE_PANEL)
1448
1449 ### Allow using a different wrap-prefix
1450 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1451         AC_MSG_CHECKING(for prefix used to wrap public variables)
1452         AC_ARG_WITH(wrap-prefix,
1453                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1454                 [NCURSES_WRAP_PREFIX=$withval],
1455                 [NCURSES_WRAP_PREFIX=_nc_])
1456         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1457 else
1458         NCURSES_WRAP_PREFIX=_nc_
1459 fi
1460 AC_SUBST(NCURSES_WRAP_PREFIX)
1461 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1462
1463 ###############################################################################
1464 # These options are relatively safe to experiment with.
1465 CF_HELP_MESSAGE(Development Code:)
1466 AC_MSG_CHECKING(if you want all development code)
1467 AC_ARG_WITH(develop,
1468         [  --without-develop       disable development options],
1469         [with_develop=$withval],
1470         [with_develop=no])
1471 AC_MSG_RESULT($with_develop)
1472
1473 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1474 AC_MSG_CHECKING(if you want hard-tabs code)
1475 AC_ARG_ENABLE(hard-tabs,
1476         [  --enable-hard-tabs      compile with hard-tabs code],,
1477         [enable_hard_tabs=$with_develop])
1478 AC_MSG_RESULT($enable_hard_tabs)
1479 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1480
1481 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1482 AC_MSG_CHECKING(if you want limited support for xmc)
1483 AC_ARG_ENABLE(xmc-glitch,
1484         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1485         [enable_xmc_glitch=$with_develop])
1486 AC_MSG_RESULT($enable_xmc_glitch)
1487 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1488
1489 ###############################################################################
1490 # These are just experimental, probably should not be in a package:
1491 CF_HELP_MESSAGE(Experimental Code:)
1492
1493 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1494 AC_ARG_ENABLE(assumed-color,
1495         [  --disable-assumed-color do not assume anything about default-colors],
1496         [with_assumed_color=$enableval],
1497         [with_assumed_color=yes])
1498 AC_MSG_RESULT($with_assumed_color)
1499 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1500
1501 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1502 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1503 AC_ARG_ENABLE(hashmap,
1504         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1505         [with_hashmap=$enableval],
1506         [with_hashmap=yes])
1507 AC_MSG_RESULT($with_hashmap)
1508 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1509
1510 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1511 AC_MSG_CHECKING(if you want code to check screensize)
1512 AC_ARG_ENABLE(check-size,
1513         [  --enable-check-size     compile-in code to detect screensize],
1514         [with_check_size=$enableval],
1515         [with_check_size=no])
1516 AC_MSG_RESULT($with_check_size)
1517 test "x$with_check_size" = xyes && AC_DEFINE(USE_CHECK_SIZE,1,[Define to 1 to compile-in code to detect screensize])
1518
1519 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1520 AC_MSG_CHECKING(if you want colorfgbg code)
1521 AC_ARG_ENABLE(colorfgbg,
1522         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1523         [with_colorfgbg=$enableval],
1524         [with_colorfgbg=no])
1525 AC_MSG_RESULT($with_colorfgbg)
1526 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1527
1528 ###   use option --enable-fvisibility to turn on use of gcc-specific feature
1529 AC_MSG_CHECKING(if you want to use gcc -fvisibility option)
1530 AC_ARG_ENABLE(fvisibility,
1531         [  --enable-fvisibility    compile with -fvisibility=hidden],
1532         [cf_with_fvisibility=$enableval],
1533         [cf_with_fvisibility=no])
1534 AC_MSG_RESULT($cf_with_fvisibility)
1535
1536 NCURSES_IMPEXP=
1537 NCURSES_CXX_IMPEXP=
1538 if test "x$cf_with_fvisibility" = xyes; then
1539         CF_CHECK_FVISIBILITY($CC,CFLAGS,cf_cv_fvisibility_hidden)
1540         if test "x$cf_cv_fvisibility_hidden" = xyes
1541         then
1542                 CF_ADD_CFLAGS([-fvisibility=hidden])
1543                 NCURSES_IMPEXP="__attribute__ ((visibility(\"default\")))"
1544         fi
1545         if test -n "$CXX"
1546         then
1547                 AC_LANG_PUSH(C++)
1548                 CF_CHECK_FVISIBILITY($CXX,CXXFLAGS,cf_cv_fvisibility_hidden2)
1549                 if test "x$cf_cv_fvisibility_hidden2" = xyes
1550                 then
1551                         CF_ADD_CXXFLAGS([-fvisibility=hidden])
1552                         NCURSES_CXX_IMPEXP="__attribute__ ((visibility(\"default\")))"
1553                 fi
1554                 AC_LANG_POP
1555         fi
1556 fi
1557 AC_SUBST(NCURSES_IMPEXP)
1558 AC_SUBST(NCURSES_CXX_IMPEXP)
1559
1560 ###   use option --enable-interop to turn on use of bindings used for interop
1561 AC_MSG_CHECKING(if you want interop bindings)
1562 AC_ARG_ENABLE(interop,
1563         [  --enable-interop        compile-in interop bindings],
1564         [with_exp_interop=$enableval],
1565         [with_exp_interop=$cf_dft_interop])
1566 AC_MSG_RESULT($with_exp_interop)
1567
1568 NCURSES_INTEROP_FUNCS=0
1569 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1570 AC_SUBST(NCURSES_INTEROP_FUNCS)
1571
1572
1573 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1574 AC_ARG_ENABLE(safe-sprintf,
1575         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1576         [with_safe_sprintf=$enableval],
1577         [with_safe_sprintf=no])
1578 AC_MSG_RESULT($with_safe_sprintf)
1579
1580 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1581 # when hashmap is used scroll hints are useless
1582 if test "$with_hashmap" = no ; then
1583 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1584 AC_ARG_ENABLE(scroll-hints,
1585         [  --disable-scroll-hints  compile without scroll-hints code],
1586         [with_scroll_hints=$enableval],
1587         [with_scroll_hints=yes])
1588 AC_MSG_RESULT($with_scroll_hints)
1589 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1590 fi
1591
1592 AC_MSG_CHECKING(if you want wgetch-events code)
1593 AC_ARG_ENABLE(wgetch-events,
1594         [  --enable-wgetch-events  compile with wgetch-events code],
1595         [with_wgetch_events=$enableval],
1596         [with_wgetch_events=no])
1597 AC_MSG_RESULT($with_wgetch_events)
1598 if test "x$with_wgetch_events" = xyes ; then
1599         AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1600         NCURSES_WGETCH_EVENTS=1
1601 else
1602         NCURSES_WGETCH_EVENTS=0
1603 fi
1604 AC_SUBST(NCURSES_WGETCH_EVENTS)
1605
1606 case "$cf_cv_system_name" in
1607 (*mingw32*|*mingw64*|*-msvc*)
1608         AC_MSG_CHECKING(if you want experimental-Windows driver)
1609         AC_ARG_ENABLE(exp-win32,
1610                 [  --enable-exp-win32      compile with experimental-Windows driver],
1611                 [with_exp_win32=$enableval],
1612                 [with_exp_win32=no])
1613         AC_MSG_RESULT($with_exp_win32)
1614         if test "x$with_exp_win32" = xyes
1615         then
1616                 AC_DEFINE(EXP_WIN32_DRIVER,1,[Define to 1 to compile with experimental win32 driver])
1617                 EXP_WIN32_DRIVER=1
1618                 INTERNALS_HDR='[$](INCDIR)/nc_win32.h'
1619         else
1620                 INTERNALS_HDR='[$](INCDIR)/nc_mingw.h'
1621                 EXP_WIN32_DRIVER=0
1622         fi
1623         ;;
1624 (*)
1625         EXP_WIN32_DRIVER=0
1626         INTERNALS_HDR=
1627         ;;
1628 esac
1629 AC_SUBST(EXP_WIN32_DRIVER)
1630 AC_SUBST(INTERNALS_HDR)
1631
1632 ###############################################################################
1633 CF_HELP_MESSAGE(Testing/development Options:)
1634
1635 ###     use option --disable-echo to suppress full display compiling commands
1636 CF_DISABLE_ECHO
1637 if test "x$enable_echo" = xyes; then
1638         ECHO_LINK=
1639 else
1640         ECHO_LINK='@ echo linking $@ ... ;'
1641         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1642         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1643 fi
1644 AC_SUBST(ECHO_LINK)
1645
1646 # --disable-stripping is used for debugging
1647 CF_INSTALL_OPTS
1648
1649 # If we're avoiding relinking of shared libraries during install, that is to
1650 # avoid modifying the build-tree.  For the same reason, avoid doing ranlib if
1651 # the install program has "-p" (for preserving timestamps).
1652 cf_cv_do_reranlib=yes
1653 if test "x$cf_cv_install_p" = xyes
1654 then
1655         if test "x$cf_cv_do_relink" != xyes
1656         then
1657                 cf_cv_do_reranlib=no
1658                 INSTALL_OPT_P="-p"
1659                 INSTALL_LIB="$INSTALL_LIB $INSTALL_OPT_P"
1660         fi
1661 fi
1662 AC_SUBST(INSTALL_OPT_P)
1663
1664 ###     use option --enable-warnings to turn on all gcc warnings
1665 CF_ENABLE_WARNINGS(Wno-unknown-pragmas Wswitch-enum,yes)
1666
1667 if test "x$enable_warnings" = "xyes"; then
1668         CF_ADD_ADAFLAGS(-gnatwa -gnatyg)
1669         if test "x$cf_with_cxx" = xyes ; then
1670                 CF_GXX_WARNINGS(Wno-unused)
1671         fi
1672 fi
1673 CF_ENABLE_STRING_HACKS
1674
1675 ###     use option --enable-assertions to turn on generation of assertion code
1676 AC_MSG_CHECKING(if you want to enable runtime assertions)
1677 AC_ARG_ENABLE(assertions,
1678         [  --enable-assertions     test: turn on generation of assertion code],
1679         [with_assertions=$enableval],
1680         [with_assertions=no])
1681 AC_MSG_RESULT($with_assertions)
1682 if test -n "$GCC"
1683 then
1684         if test "$with_assertions" = no
1685         then
1686                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1687         else
1688                 CF_ADD_ADAFLAGS(-gnata)
1689         fi
1690 fi
1691
1692 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1693 CF_DISABLE_LEAKS
1694 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1695
1696 ###     use option --enable-expanded to generate certain macros as functions
1697 AC_ARG_ENABLE(expanded,
1698         [  --enable-expanded       test: generate functions for certain macros],
1699         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1700
1701 ###     use option --disable-macros to suppress macros in favor of functions
1702 AC_ARG_ENABLE(macros,
1703         [  --disable-macros        test: use functions rather than macros],
1704         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1705
1706 # Normally we only add trace() to the debug-library.  Allow this to be
1707 # extended to all models of the ncurses library:
1708 cf_all_traces=no
1709 case "$CFLAGS $CPPFLAGS" in
1710 (*-DTRACE*)
1711         cf_all_traces=yes
1712         ;;
1713 esac
1714
1715 AC_MSG_CHECKING(whether to add trace feature to all models)
1716 AC_ARG_WITH(trace,
1717 [  --with-trace            test: add trace() function to all models of ncurses],
1718 [cf_with_trace=$withval],
1719 [cf_with_trace=$cf_all_traces])
1720 AC_MSG_RESULT($cf_with_trace)
1721
1722 if test "x$cf_with_trace" = xyes ; then
1723         LIB_TRACING=all
1724         ADA_TRACE=TRUE
1725         CF_ADD_CFLAGS(-DTRACE)
1726         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1727 else
1728         LIB_TRACING=DEBUG
1729         ADA_TRACE=FALSE
1730 fi
1731
1732 AC_SUBST(ADA_TRACE)
1733
1734 CF_DISABLE_GNAT_PROJECTS
1735
1736 ###     Checks for libraries.
1737 case "$cf_cv_system_name" in
1738 (*mingw32*|*mingw64*)
1739         # Note: WINVER may be a problem with Windows 10
1740         if test "x$with_exp_win32" = xyes ; then
1741                 CPPFLAGS="$CPPFLAGS -DWINVER=0x0600 -DWIN32_LEAN_AND_MEAN"
1742         else
1743                 CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1744         fi
1745         CF_CHECK_LIBSSP
1746         ;;
1747 (*)
1748         ;;
1749 esac
1750
1751 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1752 AC_SUBST(MATH_LIB)
1753
1754 ###     Checks for header files.
1755 AC_HEADER_TIME
1756 CF_REGEX
1757
1758 dnl These are some other potentially nonportable headers.
1759 AC_CHECK_HEADERS( \
1760 fcntl.h \
1761 getopt.h \
1762 limits.h \
1763 locale.h \
1764 math.h \
1765 poll.h \
1766 sys/auxv.h \
1767 sys/ioctl.h \
1768 sys/param.h \
1769 sys/poll.h \
1770 sys/select.h \
1771 sys/time.h \
1772 sys/times.h \
1773 unistd.h \
1774 wctype.h \
1775 )
1776
1777 CF_GETOPT_HEADER
1778
1779 CF_CHECK_ENVIRON(environ)
1780 CF_CHECK_GETENV
1781 if test "x$cf_cv_consistent_getenv" = xno && \
1782         test "x$cf_with_trace" = xyes
1783 then
1784         AC_MSG_WARN(The NCURSES_TRACE environment variable is not supported with this configuration)
1785 fi
1786
1787 CF_SYS_TIME_SELECT
1788
1789 ###     checks for compiler characteristics
1790 AC_LANG_C
1791 AC_C_CONST
1792 CF_C_INLINE(NCURSES_INLINE,1200)
1793 CF_SIG_ATOMIC_T
1794
1795 if test "$NCURSES_CHTYPE" = auto ; then
1796         CF_TYPEOF_CHTYPE
1797 else
1798         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1799 fi
1800 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1801 AC_SUBST(cf_cv_typeof_chtype)
1802
1803 CF_UNSIGNED_LITERALS
1804 cf_cv_1UL="1"
1805 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1806 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1807 AC_SUBST(cf_cv_1UL)
1808
1809 if test "$NCURSES_MMASK_T" = auto ; then
1810         cf_cv_typeof_mmask_t=long
1811 else
1812         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1813 fi
1814 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1815 AC_SUBST(cf_cv_typeof_mmask_t)
1816
1817 ###     Checks for external-data
1818 CF_ERRNO
1819 CF_LINK_DATAONLY
1820
1821 ###     Checks for library functions.
1822 CF_FUNC_GETTIME
1823 AC_CHECK_FUNCS( \
1824 fpathconf \
1825 getcwd \
1826 getauxval \
1827 getegid \
1828 geteuid \
1829 getopt \
1830 getuid \
1831 issetugid \
1832 localeconv \
1833 poll \
1834 putenv \
1835 remove \
1836 select \
1837 setbuf \
1838 setbuffer \
1839 setenv \
1840 setfsuid \
1841 setvbuf \
1842 sigaction \
1843 sigvec \
1844 snprintf \
1845 strdup \
1846 strstr \
1847 sysconf \
1848 tcgetpgrp \
1849 times \
1850 tsearch \
1851 vsnprintf \
1852 )
1853
1854 CF_FUNC_GETTTYNAM
1855
1856 if test "x$ac_cv_func_getopt" = xno && \
1857    test "x$cf_with_progs$cf_with_tests" != xnono; then
1858         AC_MSG_ERROR(getopt is required for building programs)
1859 fi
1860
1861 if test "x$with_safe_sprintf" = xyes
1862 then
1863         if test "x$ac_cv_func_vsnprintf" = xyes
1864         then
1865                 AC_MSG_WARN(will use vsnprintf instead of safe-sprintf option)
1866         else
1867                 AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1868         fi
1869 fi
1870
1871 if test "x$with_getcap" = "xyes" ; then
1872         CF_CGETENT
1873 fi
1874
1875 CF_ISASCII
1876 CF_STRUCT_SIGACTION
1877 CF_FUNC_NANOSLEEP
1878 CF_FUNC_TERMIOS
1879 CF_FUNC_VSSCANF
1880 CF_MKSTEMP
1881
1882 # setup for prototype of fallback for vsscanf()
1883 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1884
1885 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1886 if test "x$cross_compiling" = xyes ; then
1887         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1888 else
1889         AC_FUNC_SETVBUF_REVERSED
1890 fi
1891 AC_CHECK_TYPE(intptr_t, long)
1892 AC_CHECK_TYPE(ssize_t, int)
1893 CF_TYPE_SIGACTION
1894 CF_SIZECHANGE
1895 CF_FUNC_MEMMOVE
1896 CF_FUNC_POLL
1897 CF_VA_COPY
1898 AC_FUNC_VFORK
1899 CF_FOPEN_BIN_R
1900
1901 # special check for test/ditto.c
1902 CF_FUNC_OPENPTY
1903 if test "$cf_cv_func_openpty" != no ; then
1904         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1905         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1906         if test "x$cf_cv_lib_util" = xyes ; then
1907                 CF_ADD_LIB(util,TEST_LIBS)
1908         fi
1909 fi
1910 AC_SUBST(TEST_LIBS)
1911 AC_SUBST(TEST_LIBS2)
1912
1913 if test "$with_hashed_db" != no ; then
1914         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1915         CF_HASHED_DB($with_hashed_db)
1916 fi
1917
1918 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1919 if test -z "$cf_user_CFLAGS" && test "$enable_leaks" = yes ; then
1920         CF_STRIP_G_OPT(CFLAGS)
1921         CF_STRIP_G_OPT(CXXFLAGS)
1922 fi
1923
1924 # Just in case, check if the C compiler has a bool type.
1925 CF_BOOL_DECL(cf_cv_cc_bool_type)
1926
1927 # Check for C++ compiler characteristics (and ensure that it's there!)
1928 if test -n "$CXX" ; then
1929         AC_LANG_CPLUSPLUS
1930         CF_STDCPP_LIBRARY
1931         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1932
1933         case "$GXX_VERSION" in
1934         (1.*|2.[[0-6]]*|[[1-9]][[0-9]].*)
1935                 cf_cxx_library=yes
1936                 ;;
1937         (*-2.7*|2.7*)
1938                 CF_GPP_LIBRARY
1939                 ;;
1940         (*)
1941                 cf_cxx_library=no
1942                 ;;
1943         esac
1944
1945         AC_CHECK_HEADERS(typeinfo)
1946         CF_CXX_IOSTREAM_NAMESPACE
1947         CF_BOOL_DECL
1948         CF_BOOL_SIZE
1949         CF_ETIP_DEFINES
1950         CF_CPP_OVERRIDE
1951         CF_CPP_PARAM_INIT
1952         CF_CPP_STATIC_CAST
1953         CF_CXX_AR_FLAGS
1954 else
1955         cf_cxx_library=no
1956         cf_cv_builtin_bool=1
1957
1958         # Just because we are not configuring against C++ right now does not
1959         # mean that a user will not want to use C++.  Some distributors disable
1960         # the C++ portion of this configuration as a shortcut (or just to avoid
1961         # compiling the demo in the c++ directory).  So we need a reasonable
1962         # default for the 'bool' type.
1963         #
1964         # Caveat: since the storage of the bool type is not standardized, it
1965         # may change.
1966
1967         if test "$NCURSES_BOOL" != auto ; then
1968                 cf_cv_type_of_bool=$NCURSES_BOOL
1969                 cf_cv_header_stdbool_h=0
1970         else
1971                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1972                         CF_BOOL_SIZE
1973                 else
1974                         AC_MSG_CHECKING(for fallback type of bool)
1975                         case "$host_cpu" in
1976                         (i?86)  cf_cv_type_of_bool=char ;;
1977                         (*)     cf_cv_type_of_bool=int  ;;
1978                         esac
1979                         AC_MSG_RESULT($cf_cv_type_of_bool)
1980                 fi
1981         fi
1982 fi
1983 AC_SUBST(CXXLIBS)
1984
1985 # If the C compiler did not declare bool, and we did not determine that the C++
1986 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1987 # ncurses library use the same type as C++ bool.  Note that this allows one to
1988 # specify the type of bool in a configure-script option and postpone
1989 # integration with the C++ compiler provided that the types are compatible.
1990 USE_CXX_BOOL=1
1991 if test "$cf_cv_cc_bool_type" = 1
1992 then
1993         # oops: C has a bool.  Unlikely, but C++ could differ.
1994         USE_CXX_BOOL=0
1995 elif test "$cf_cv_builtin_bool" = 0
1996 then
1997         # C++ has no bool
1998         USE_CXX_BOOL=0
1999 else
2000         # this is the normal case
2001         USE_CXX_BOOL='defined(__cplusplus)'
2002 fi
2003 AC_SUBST(USE_CXX_BOOL)
2004
2005 CF_HELP_MESSAGE(Ada Binding Options:)
2006
2007 dnl If the Ada95 source-tree is present, add that to the build unless it will
2008 dnl not work, or was not requested.
2009 if test -f "${srcdir}/Ada95/Makefile.in" ; then
2010
2011 dnl libtool does not know anything about GNAT, though a change made in 1998
2012 dnl provided for it "someday".  Disable the ada subtree if we are using
2013 dnl libtool -TD 20070714
2014         if test "$cf_with_ada" != "no" ; then
2015                 if test "$with_libtool" != "no"; then
2016                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
2017                         cf_with_ada=no
2018                 fi
2019         fi
2020
2021 dnl Check for availability of GNU Ada Translator (GNAT).
2022 dnl At the moment we support no other Ada compiler.
2023         if test "$cf_with_ada" != "no" ; then
2024                 CF_PROG_GNAT
2025                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
2026                         CF_ADD_ADAFLAGS(-gnatpn)
2027                         CF_FIXUP_ADAFLAGS
2028
2029                         CF_GNATPREP_OPT_T
2030
2031                         CF_GNAT_GENERICS
2032                         CF_GNAT_SIGINT
2033                         CF_GNAT_PROJECTS
2034
2035                         CF_WITH_ADA_COMPILER
2036
2037                         cf_ada_package=terminal_interface
2038                         AC_SUBST(cf_ada_package)
2039
2040                         CF_WITH_ADA_INCLUDE
2041                         CF_WITH_ADA_OBJECTS
2042                         CF_WITH_ADA_SHAREDLIB
2043
2044                         # allow the Ada binding to be renamed
2045                         CF_WITH_ADA_LIBNAME(AdaCurses)
2046                 fi
2047         fi
2048 else
2049         cf_with_ada=no
2050 fi
2051
2052 # do this "late" to avoid conflict with header-checks
2053 if test "x$with_widec" = xyes ; then
2054         AC_CHECK_SIZEOF(wchar_t)
2055         # cross-compiling to mingw can run into the problem that attempting to
2056         # link with the regex library fails, causing the test to not set this to
2057         # a number.  "recent" autoconf does not address this problem either -TD
2058         if test -z "$ac_cv_sizeof_wchar_t"
2059         then
2060                 CF_VERBOSE(test failed (assume 2))
2061                 sed /SIZEOF_WCHAR_T/d confdefs.h >confdefs.tmp
2062                 mv confdefs.tmp confdefs.h
2063                 echo "#define SIZEOF_WCHAR_T 2" >>confdefs.h
2064         fi
2065 fi
2066
2067 ### Construct the ncurses library-subsets, if any, from this set of keywords:
2068 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
2069 ###
2070 ### ticlib modules may be a separate library, otherwise contained in termlib.
2071 ### termlib modules may be a separate library, otherwise contained in ncurses.
2072 ###
2073 ### The of "+" or " " between the tokens controls the way the script
2074 ### chooses to split module lists into libraries.
2075 ###
2076 ### (see CF_LIB_RULES).
2077 AC_MSG_CHECKING(for library subsets)
2078 LIB_SUBSETS=
2079
2080 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
2081         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
2082         if test "$with_ticlib" != no ; then
2083                 LIB_SUBSETS="${LIB_SUBSETS} "
2084         else
2085                 LIB_SUBSETS="${LIB_SUBSETS}+"
2086         fi
2087 fi
2088
2089 LIB_SUBSETS="${LIB_SUBSETS}termlib"
2090 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
2091
2092 if test "$with_termlib" != no ; then
2093         LIB_SUBSETS="${LIB_SUBSETS} "
2094 else
2095         LIB_SUBSETS="${LIB_SUBSETS}+"
2096 fi
2097
2098 LIB_SUBSETS="${LIB_SUBSETS}base"
2099
2100 # Most term-driver calls are to tinfo, but some like init_pair are to the
2101 # base library (so it resides in base).
2102 if test "$with_term_driver" != no ; then
2103         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
2104         case "$cf_cv_system_name" in
2105         (*mingw32*|*mingw64*)
2106                 if test "x$with_exp_win32" = xyes ; then
2107                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32"
2108                 else
2109                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
2110                 fi
2111                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
2112                 ;;
2113         (*)
2114                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
2115                 ;;
2116         esac
2117 elif test "x$with_exp_win32" = xyes ; then
2118         case "$cf_cv_system_name" in
2119         (*mingw32*|*mingw64*)
2120                 LIB_SUBSETS="${LIB_SUBSETS}+port_win32"
2121                 ;;
2122         (*)
2123                 ;;
2124         esac
2125 fi
2126
2127 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
2128 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
2129
2130 AC_MSG_RESULT($LIB_SUBSETS)
2131
2132 ### Construct the list of include-directories to be generated
2133 CF_INCLUDE_DIRS
2134 CF_ADA_INCLUDE_DIRS
2135
2136 ### Build up pieces for makefile rules
2137 AC_MSG_CHECKING(default library suffix)
2138 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
2139 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
2140 AC_MSG_RESULT($DFT_ARG_SUFFIX)
2141
2142 AC_MSG_CHECKING(default library-dependency suffix)
2143 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
2144 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
2145 AC_MSG_RESULT($DFT_DEP_SUFFIX)
2146
2147 AC_MSG_CHECKING(default object directory)
2148 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
2149 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
2150 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
2151
2152 if test "x$cf_with_cxx" = xyes ; then
2153 AC_MSG_CHECKING(c++ library-dependency suffix)
2154 if test "$with_libtool" != "no"; then
2155         # libtool thinks it can make c++ shared libraries (perhaps only g++)
2156         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2157 elif test "$with_shared_cxx" != "no"; then
2158         # also for g++ users...
2159         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2160 else
2161         # we normally make a static library because C/C++ library rules differ
2162         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
2163 fi
2164 AC_MSG_RESULT($CXX_LIB_SUFFIX)
2165 AC_SUBST(CXX_LIB_SUFFIX)
2166 fi
2167
2168 # do not want -ldl in build except as needed for -lncurses dependency
2169 if test "x$with_dlsym" = xyes ; then
2170 if test "$DFT_LWR_MODEL" = shared || \
2171    test "$DFT_LWR_MODEL" = libtool ; then
2172         CF_REMOVE_LIB(LIBS,$LIBS,dl)
2173 fi
2174 fi
2175 ### Set up low-level terminfo dependencies for makefiles.
2176
2177 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
2178 # do not need libdl
2179 TICS_LIST=
2180 if test "x$with_dlsym" = xyes ; then
2181         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
2182 fi
2183
2184 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
2185 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
2186 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
2187 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
2188 then
2189         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
2190 fi
2191 AC_SUBST(USE_ARG_SUFFIX)
2192 AC_SUBST(USE_CFG_SUFFIX)
2193 AC_SUBST(USE_LIB_SUFFIX)
2194
2195 if test "$with_ticlib" != no ; then
2196
2197         if test "x$with_ticlib" != xyes ; then
2198                 TICS_NAME=$with_ticlib
2199                 TICS_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2200                 TICS_ARG_SUFFIX="${with_ticlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2201                 TICS_DEP_SUFFIX="${with_ticlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2202                 TICS_LIB_SUFFIX="${with_ticlib}"
2203         else
2204                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
2205                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
2206                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
2207                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
2208         fi
2209         TICS_LDFLAGS="-L${LIB_DIR}"
2210         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
2211 else
2212         TICS_SUFFIX=${DFT_LIB_SUFFIX}
2213         TICS_LDFLAGS="-L${LIB_DIR}"
2214         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2215 fi
2216 AC_SUBST(TICS_ARG_SUFFIX)
2217 AC_SUBST(TICS_DEP_SUFFIX)
2218 AC_SUBST(TICS_LIB_SUFFIX)
2219 AC_SUBST(TICS_LDFLAGS)
2220 AC_SUBST(TICS_LIBS)
2221
2222 if test "$with_termlib" != no ; then
2223
2224         if test "x$with_termlib" != xyes ; then
2225                 TINFO_NAME=$with_termlib
2226                 TINFO_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2227                 TINFO_ARG_SUFFIX="${with_termlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2228                 TINFO_DEP_SUFFIX="${with_termlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2229                 TINFO_LIB_SUFFIX="${with_termlib}"
2230         else
2231                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2232                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2233                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2234                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2235         fi
2236
2237         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2238         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2239         if test "$DFT_LWR_MODEL" = "libtool"; then
2240                 TEST_ARGS="${TEST_DEPS}"
2241                 TEST_ARG2="${TEST_DEP2}"
2242                 TINFO_LDFLAGS="-L${LIB_DIR}"
2243                 TINFO_LIBS="$TEST_ARGS"
2244                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2245                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2246         else
2247                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2248                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2249                 if test "x$with_term_driver" != xno ; then
2250                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2251                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2252                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2253                 else
2254                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2255                         TINFO_LIBS="$TEST_ARGS"
2256                 fi
2257                 TINFO_LDFLAGS="-L${LIB_DIR}"
2258                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2259         fi
2260 else
2261         # the next lines are needed for linking libtic over libncurses
2262         TINFO_NAME=${LIB_NAME}
2263         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2264         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2265         if test "x$with_tic_depends" = xyes ; then
2266                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2267         else
2268                 TICS_LIST="$SHLIB_LIST"
2269         fi
2270
2271         TINFO_LDFLAGS="-L${LIB_DIR}"
2272         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2273 fi
2274
2275 if test "$DFT_LWR_MODEL" = shared ; then
2276         case "$cf_cv_system_name" in
2277         (cygwin*|msys*)
2278                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2279                 TINFO_SUFFIX=.dll
2280                 ;;
2281         esac
2282 fi
2283
2284 AC_SUBST(TINFO_ARG_SUFFIX)
2285 AC_SUBST(TINFO_DEP_SUFFIX)
2286 AC_SUBST(TINFO_LIB_SUFFIX)
2287 AC_SUBST(TINFO_LDFLAGS)
2288 AC_SUBST(TINFO_LIBS)
2289
2290 if test "x$with_dlsym" = xyes ; then
2291         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2292 fi
2293
2294 if test "$DFT_LWR_MODEL" = "libtool"; then
2295         OBJEXT=lo
2296 fi
2297
2298 # needed for Ada95
2299 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2300 AC_SUBST(TINFO_LDFLAGS2)
2301
2302 case "$DFT_LWR_MODEL" in
2303 (normal|debug|profile)
2304         CF_LDFLAGS_STATIC
2305         ;;
2306 esac
2307
2308 AC_MSG_CHECKING(where we will install curses.h)
2309 AC_SUBST(includesubdir)
2310 includesubdir=
2311 if test "$with_overwrite" = no && \
2312  { test "x$includedir" = 'x${prefix}/include' || \
2313    test "x$includedir" = "x${prefix}/include"; }
2314 then
2315         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2316 fi
2317 AC_MSG_RESULT(${includedir}${includesubdir})
2318
2319 ### Resolve a conflict between normal and wide-curses by forcing applications
2320 ### that will need libutf8 to add it to their configure script.
2321 if test "$with_overwrite" != no ; then
2322 if test "$NCURSES_LIBUTF8" = 1 ; then
2323         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2324         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2325 fi
2326 fi
2327 WITH_OVERWRITE=$with_overwrite
2328
2329 ### At least on MinGW a shared library build without libtool
2330 ### requires adding the additional libs to the link list.
2331 case "$cf_cv_system_name" in
2332 (*mingw32*|*mingw64*)
2333         if test "$DFT_LWR_MODEL" != "libtool"; then
2334            SHLIB_LIST="$SHLIB_LIST ${LIBS}"
2335         fi
2336         ;;
2337 *)      ;;
2338 esac
2339
2340 AC_SUBST(WITH_OVERWRITE)
2341 AC_SUBST(TICS_LIST)
2342 AC_SUBST(TINFO_LIST)
2343 AC_SUBST(SHLIB_LIST)
2344
2345 ### predefined stuff for the test programs
2346 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2347
2348 # pkgsrc uses these
2349 CF_HELP_MESSAGE(Library basenames for pkgsrc:)
2350 CF_WITH_LIB_BASENAME(FORM_NAME,form)
2351 CF_WITH_LIB_BASENAME(MENU_NAME,menu)
2352 CF_WITH_LIB_BASENAME(PANEL_NAME,panel)
2353 CF_WITH_LIB_BASENAME(CXX_NAME,cxx,ncurses++)
2354
2355 ### Construct the list of subdirectories for which we'll customize makefiles
2356 ### with the appropriate compile-rules.
2357
2358 CF_SRC_MODULES($modules_to_build)
2359
2360 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2361    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/src/library.gpr:Ada95/src/library.gpr.in"
2362    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2363    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2364 fi
2365
2366 CF_DIRS_TO_MAKE
2367
2368 # symbols that differ when compiling Ada95 by itself.
2369 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2370 AC_SUBST(NCURSES_SHLIB2)
2371
2372 # values to use as strings
2373 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2374
2375 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2376
2377 ### Define substitutions for header files to avoid name-pollution
2378 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2379 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2380 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2381 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2382
2383 ################################################################################
2384 test "x$use_database" = xyes && \
2385 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2386
2387 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2388 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2389
2390 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2391 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2392 fi
2393 AC_SUBST(cross_compiling)
2394
2395 if test "x$cf_with_tests" != xno ; then
2396         MAKE_TESTS=
2397 else
2398         MAKE_TESTS="#"
2399 fi
2400 AC_SUBST(MAKE_TESTS)
2401
2402 ADAHTML_DIR=../../doc/html/ada
2403 AC_SUBST(ADAHTML_DIR)
2404
2405 # workaround for OS/2 (20151017)
2406 case "$cf_cv_system_name" in
2407 (os2*)
2408         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2409         ;;
2410 (*)
2411         LIBTOOL_OPTS_CXX=
2412         ;;
2413 esac
2414 AC_SUBST(LIBTOOL_OPTS_CXX)
2415
2416 # workaround for g++ versus Solaris (20131116)
2417 case "$cf_cv_system_name" in
2418 (solaris2*)
2419         case "x$CPPFLAGS" in
2420         (*-D_XOPEN_SOURCE_EXTENDED*)
2421                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2422                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2423                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2424                 ;;
2425         esac
2426         ;;
2427 esac
2428
2429 # Help to automatically enable the extended curses features when using either
2430 # the *-config or the ".pc" files by adding defines.
2431 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}${cf_config_suffix}-config script)
2432 PKG_CFLAGS=
2433 for cf_loop1 in $CPPFLAGS_after_XOPEN
2434 do
2435         cf_found=no
2436         for cf_loop2 in $CPPFLAGS_before_XOPEN
2437         do
2438                 if test "x$cf_loop1" = "x$cf_loop2"
2439                 then
2440                         cf_found=yes
2441                         break
2442                 fi
2443         done
2444         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2445 done
2446 AC_MSG_RESULT($PKG_CFLAGS)
2447 AC_SUBST(PKG_CFLAGS)
2448
2449 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2450 case "x$NCURSES_OSPEED" in
2451 (*short*)
2452         cf_compatible=1
2453         ;;
2454 (*)
2455         cf_compatible=0
2456         ;;
2457 esac
2458 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2459
2460 case "x$cf_cv_typeof_chtype" in
2461 (xshort|xint|xlong)
2462         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2463         ;;
2464 esac
2465
2466 case "x$cf_cv_typeof_mmask_t" in
2467 (xshort|xint|xlong)
2468         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2469         ;;
2470 esac
2471
2472 # substitute into misc/Makefile to suppress
2473 # (un)install.data from the
2474 # (un)install rules.
2475 if test "x$cf_with_db_install" = "xno"; then
2476         MISC_INSTALL_DATA=
2477         MISC_UNINSTALL_DATA=
2478 else
2479         MISC_INSTALL_DATA=install.data
2480         MISC_UNINSTALL_DATA=uninstall.data
2481 fi
2482 AC_SUBST(MISC_INSTALL_DATA)
2483 AC_SUBST(MISC_UNINSTALL_DATA)
2484
2485 if test "x$cf_with_db_install" = "xno" || test "x$TERMINFO_SRC" = "xno"; then
2486         MAKE_DATABASE="#"
2487 else
2488         MAKE_DATABASE="$MAKE_TERMINFO"
2489 fi
2490 AC_SUBST(MAKE_DATABASE)
2491
2492 dnl Override the package used for exported symbols
2493 if test -n "$PACKAGE"
2494 then
2495         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2496         export PACKAGE
2497         echo "package: $PACKAGE"
2498 fi
2499
2500 UNALTERED_SYMS=
2501 cf_filter_syms=no
2502
2503 if test -n "$RESULTING_SYMS"
2504 then
2505         cf_filter_syms=$cf_dft_filter_syms
2506         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_default)
2507 fi
2508
2509 if test "x$WILDCARD_SYMS" = xno
2510 then
2511         cf_filter_syms=yes
2512 fi
2513
2514 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2515
2516 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2517 if test "$cf_filter_syms" = yes
2518 then
2519         RESULTING_SYMS=resulting.map
2520 fi
2521 AC_SUBST(UNALTERED_SYMS)
2522
2523 if test "x$cross_compiling" = xyes ; then
2524         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2525         CHECK_BUILD="#"
2526 else
2527         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2528         CHECK_BUILD=
2529 fi
2530 AC_SUBST(ADAGEN_LDFLAGS)
2531 AC_SUBST(CHECK_BUILD)
2532 AC_SUBST(PRIVATE_LIBS)
2533
2534 # This is used for the *-config script and *.pc data files.
2535 CF_LD_SEARCHPATH
2536
2537 AC_OUTPUT( \
2538         include/MKterm.h.awk \
2539         include/curses.head:include/curses.h.in \
2540         include/ncurses_dll.h \
2541         include/termcap.h \
2542         include/unctrl.h \
2543         man/man_db.renames \
2544         $SUB_MAKEFILES \
2545         Makefile,[
2546 if test "x$cf_with_tests" != xno ; then
2547         CF_PRG_RULES(["$srcdir/test/mk-test.awk" INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2548 fi
2549 CF_LIB_RULES($SRC_SUBDIRS)
2550 CF_OUTPUT_MANPAGE_RENAMES
2551
2552 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2553 if test -z "$USE_OLD_MAKERULES" ; then
2554         $AWK -f "$srcdir/Ada95/mk-1st.awk" <"$srcdir/Ada95/src/modules" >>Ada95/src/Makefile
2555 fi
2556 fi
2557 ],[
2558 ### Special initialization commands, used to pass information from the
2559 ### configuration-run into config.status
2560
2561 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2562 AWK="$AWK"
2563 CXX_NAME="$CXX_NAME"
2564 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2565 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2566 ECHO_LD="$ECHO_LD"
2567 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2568 FORM_NAME="$FORM_NAME"
2569 LDCONFIG="$LDCONFIG"
2570 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2571 LIB_NAME="$LIB_NAME"
2572 LIB_PREFIX="$LIB_PREFIX"
2573 LIB_SUBSETS="$LIB_SUBSETS"
2574 LIB_SUFFIX="$LIB_SUFFIX"
2575 LIB_TRACING="$LIB_TRACING"
2576 LN_S="$LN_S"
2577 MAKE_TERMINFO="$MAKE_TERMINFO"
2578 MANPAGE_RENAMES="$MANPAGE_RENAMES"
2579 MENU_NAME="$MENU_NAME"
2580 NCURSES_MAJOR="$NCURSES_MAJOR"
2581 NCURSES_MINOR="$NCURSES_MINOR"
2582 NCURSES_OSPEED="$NCURSES_OSPEED"
2583 NCURSES_PATCH="$NCURSES_PATCH"
2584 PANEL_NAME="$PANEL_NAME"
2585 SRC_SUBDIRS="$SRC_SUBDIRS"
2586 TERMINFO="$TERMINFO"
2587 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2588 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2589 TICS_NAME="$TICS_NAME"
2590 TICS_SUFFIX="$TICS_SUFFIX"
2591 TIC_PATH="$TIC_PATH"
2592 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2593 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2594 TINFO_NAME="$TINFO_NAME"
2595 TINFO_SUFFIX="$TINFO_SUFFIX"
2596 UNALTERED_SYMS="$UNALTERED_SYMS"
2597 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2598 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2599 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2600 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2601 WILDCARD_SYMS="$WILDCARD_SYMS"
2602 WITH_CURSES_H="$with_curses_h"
2603 WITH_ECHO="${enable_echo:=yes}"
2604 WITH_OVERWRITE="$with_overwrite"
2605 cf_LIST_MODELS="$cf_list_models"
2606 cf_cv_VERSION_GNATMAKE=$cf_cv_VERSION_GNATMAKE
2607 cf_cv_VERSION_GPRBUILD=$cf_cv_VERSION_GPRBUILD
2608 cf_cv_abi_default="$cf_cv_abi_default"
2609 cf_cv_abi_version="$cf_cv_abi_version"
2610 cf_cv_do_relink="$cf_cv_do_relink"
2611 cf_cv_do_reranlib="$cf_cv_do_reranlib"
2612 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2613 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2614 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2615 cf_cv_make_PHONY="$cf_cv_make_PHONY"
2616 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2617 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2618 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2619 cf_cv_rel_version="$cf_cv_rel_version"
2620 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2621 cf_cv_shared_soname='$cf_cv_shared_soname'
2622 cf_cv_shlib_version="$cf_cv_shlib_version"
2623 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2624 cf_cv_system_name="$cf_cv_system_name"
2625 cf_cv_term_driver="$with_term_driver"
2626 cf_with_ada="$cf_with_ada"
2627 cf_with_cxx_binding="$cf_with_cxx_binding"
2628 cf_with_db_install="$cf_with_db_install"
2629 cf_with_manpages="$cf_with_manpages"
2630 cf_with_tests="$cf_with_tests"
2631 host="$host"
2632 target="$target"
2633 verbose="$verbose"
2634 with_shared_cxx="$with_shared_cxx"
2635
2636 ],cat)dnl
2637 ${MAKE:-make} preinstall