ncurses 6.2 - patch 20200831
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright 2018-2019,2020 Thomas E. Dickey                                *
3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
4 dnl                                                                          *
5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
6 dnl copy of this software and associated documentation files (the            *
7 dnl "Software"), to deal in the Software without restriction, including      *
8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
10 dnl copies of the Software, and to permit persons to whom the Software is    *
11 dnl furnished to do so, subject to the following conditions:                 *
12 dnl                                                                          *
13 dnl The above copyright notice and this permission notice shall be included  *
14 dnl in all copies or substantial portions of the Software.                   *
15 dnl                                                                          *
16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
23 dnl                                                                          *
24 dnl Except as contained in this notice, the name(s) of the above copyright   *
25 dnl holders shall not be used in advertising or otherwise to promote the     *
26 dnl sale, use or other dealings in this Software without prior written       *
27 dnl authorization.                                                           *
28 dnl***************************************************************************
29 dnl
30 dnl Author: Thomas E. Dickey 1995-on
31 dnl
32 dnl $Id: configure.in,v 1.721 2020/08/29 22:40:49 tom Exp $
33 dnl Process this file with autoconf to produce a configure script.
34 dnl
35 dnl For additional information, see
36 dnl     https://invisible-island.net/autoconf/
37 dnl     https://invisible-island.net/autoconf/my-autoconf.html
38 dnl
39 dnl ---------------------------------------------------------------------------
40 AC_PREREQ(2.52.20200111)
41 AC_REVISION($Revision: 1.721 $)
42 AC_INIT(ncurses/base/lib_initscr.c)
43 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
44
45 AC_DEFUN([AC_PATH_XTRA],[])dnl ignore dependencies on this
46
47 CF_TOP_BUILDDIR
48 CF_SUBST_NCURSES_VERSION
49 CF_VERSION_INFO(NCURSES,ncurses)
50
51 CF_WITH_REL_VERSION(NCURSES)
52 CF_NCURSES_WITH_ABI_VERSION
53
54 CF_WITH_SYSTYPE
55
56 ###     Save the given $CFLAGS to allow user-override.
57 cf_user_CFLAGS="$CFLAGS"
58
59 ###     Default install-location
60 CF_CFG_DEFAULTS
61 ### Defaults for ncurses ABI
62 CF_ABI_DEFAULTS
63
64 ###     Checks for programs.
65 AC_ARG_WITH(ada,
66         [  --without-ada           suppress check for Ada compiler, don't build demo],
67         [cf_with_ada=$withval],
68         [cf_with_ada=yes])
69
70 if test "x$cf_with_ada" = xyes
71 then
72         cf_prog_cc="gnatgcc gcc cc"
73 else
74         cf_prog_cc="gcc cc"
75 fi
76 CF_PROG_CC($cf_prog_cc)
77
78 AC_PROG_CPP
79 AC_PROG_GCC_TRADITIONAL
80 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
81 CF_PROG_LDCONFIG
82
83 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
84 dnl                             configure script by not letting us test if C++
85 dnl                             is present, making this option necessary.
86 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
87 AC_ARG_WITH(cxx,
88         [  --without-cxx           do not adjust ncurses bool to match C++],
89         [cf_with_cxx=$withval],
90         [cf_with_cxx=yes])
91 AC_MSG_RESULT($cf_with_cxx)
92 if test "X$cf_with_cxx" = Xno ; then
93         CXX=""
94         GXX=""
95 else
96         # with autoconf 2.13, we can change the error to a warning:
97         pushdef([AC_MSG_ERROR],
98                 [AC_MSG_RESULT(no)
99                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
100                 cf_with_cxx=no; CXX=""; GXX="";])dnl
101         AC_PROG_CXX
102         popdef([AC_MSG_ERROR])dnl
103
104         AC_LANG_PUSH(C++)
105         if test "x$cf_with_cxx" != xno
106         then
107                 # Several of the C++ configurations do not work, particularly when
108                 # cross-compiling (20140913 -TD)
109                 AC_MSG_CHECKING(if $CXX works)
110
111                 save_CPPFLAGS="$CPPFLAGS"
112                 eval cf_includedir=${includedir}
113                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
114                 AC_TRY_COMPILE([
115 #include <stdlib.h>
116 #include <stdio.h>
117 ],
118                 [
119                 printf("Hello world!\n")
120                 ],
121                 [cf_cxx_works=yes],
122                 [cf_cxx_works=no])
123                 CPPFLAGS="$save_CPPFLAGS"
124
125                 AC_MSG_RESULT($cf_cxx_works)
126                 if test "x$cf_cxx_works" = xno
127                 then
128                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
129                         cf_with_cxx=no; CXX=""; GXX="";
130                 fi
131         fi
132         AC_LANG_POP
133
134         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
135         if test "$CXX" = "g++" ; then
136                 AC_PATH_PROG(CXX,g++)
137         fi
138         case "x$CXX" in
139         (x|xg++)
140                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
141                 cf_with_cxx=no; CXX=""; GXX="";
142                 ;;
143         esac
144 fi
145
146 CF_GXX_VERSION
147 case $GXX_VERSION in
148 ([[1-9]][[0-9]].*)
149         ;;
150 (1.*|2.[[0-6]]*)
151         AC_MSG_WARN(templates do not work)
152         ;;
153 esac
154
155 AC_MSG_CHECKING(if you want to build C++ binding and demo)
156 AC_ARG_WITH(cxx-binding,
157         [  --without-cxx-binding   do not build C++ binding and demo],
158         [cf_with_cxx_binding=$withval],
159         [cf_with_cxx_binding=$cf_with_cxx])
160 AC_MSG_RESULT($cf_with_cxx_binding)
161
162 AC_MSG_CHECKING(if you want to build with Ada)
163 AC_MSG_RESULT($cf_with_ada)
164
165 AC_MSG_CHECKING(if you want to install terminal database)
166 AC_ARG_ENABLE(db-install,
167         [  --disable-db-install    suppress install of terminal database],
168         [cf_with_db_install=$enableval],
169         [cf_with_db_install=yes])
170 AC_MSG_RESULT($cf_with_db_install)
171
172 AC_MSG_CHECKING(if you want to install manpages)
173 AC_ARG_WITH(manpages,
174         [  --without-manpages      suppress install of manpages],
175         [cf_with_manpages=$withval],
176         [cf_with_manpages=yes])
177 AC_MSG_RESULT($cf_with_manpages)
178
179 AC_MSG_CHECKING(if you want to build programs such as tic)
180 AC_ARG_WITH(progs,
181         [  --without-progs         suppress build/install with programs (e.g., tic)],
182         [cf_with_progs=$withval],
183         [cf_with_progs=yes])
184 AC_MSG_RESULT($cf_with_progs)
185
186 if test -f $srcdir/tack/tack.h; then
187         if test "x$cross_compiling" = xyes ; then
188                 CF_VERBOSE(ignoring tack because we are cross-compiling)
189                 cf_with_tack=no
190         else
191                 AC_MSG_CHECKING(if you want to build the tack program)
192                 AC_ARG_WITH(tack,
193                         [  --without-tack          suppress build/install with tack program],
194                         [cf_with_tack=$withval],
195                         [cf_with_tack=$cf_with_progs])
196                 AC_MSG_RESULT($cf_with_tack)
197         fi
198 else
199         cf_with_tack=no
200 fi
201
202 AC_MSG_CHECKING(if you want to build test-programs)
203 AC_ARG_WITH(tests,
204         [  --without-tests         suppress build/install with test-programs],
205         [cf_with_tests=$withval],
206         [cf_with_tests=yes])
207 AC_MSG_RESULT($cf_with_tests)
208
209 AC_MSG_CHECKING(if you wish to install curses.h)
210 AC_ARG_WITH(curses-h,
211         [  --without-curses-h      install curses.h as ncurses.h only],
212         [with_curses_h=$withval],
213         [with_curses_h=yes])
214 AC_MSG_RESULT($with_curses_h)
215
216 modules_to_build="ncurses"
217 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
218 test "X$cf_with_tack"  != Xno && modules_to_build="$modules_to_build tack"
219 modules_to_build="$modules_to_build panel menu form"
220
221 AC_ARG_PROGRAM
222
223 CF_PROG_AWK
224 CF_PROG_EGREP
225 CF_PROG_INSTALL
226 CF_PROG_LINT
227 CF_PROG_LN_S
228
229 AC_SYS_LONG_FILE_NAMES
230
231 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
232 # of package conflict.
233 cf_config_suffix=
234 AC_ARG_WITH(config-suffix,
235         [  --with-config-suffix=X  suffixes ncursesXX-config file],
236         [case "x$withval" in
237         (xyes|xno)
238                 AC_MSG_WARN(expected a value for config-suffix option)
239                 ;;
240         (*)     cf_config_suffix="$withval"
241                 ;;
242         esac])
243 AC_SUBST(cf_config_suffix)
244
245 # If we find pkg-config, check if we should install the ".pc" files.
246 CF_PKG_CONFIG
247 CF_WITH_PKG_CONFIG_LIBDIR
248 CF_ENABLE_PC_FILES
249 if test -z "$MAKE_PC_FILES"
250 then
251         AC_MSG_CHECKING(for suffix to add to pc-files)
252 AC_ARG_WITH(pc-suffix,
253         [  --with-pc-suffix        suffixes pc-files],
254         [case "x$withval" in
255         (xyes|xno)
256                 PC_MODULE_SUFFIX=
257                 ;;
258         (*)     PC_MODULE_SUFFIX="$withval"
259                 ;;
260         esac])
261         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
262         AC_MSG_RESULT($PC_MODULE_SUFFIX)
263         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
264         AC_SUBST(PC_MODULE_SUFFIX)
265 fi
266
267 AC_MSG_CHECKING(if we should assume mixed-case filenames)
268 AC_ARG_ENABLE(mixed-case,
269         [  --enable-mixed-case     tic should assume mixed-case filenames],
270         [enable_mixedcase=$enableval],
271         [enable_mixedcase=auto])
272 AC_MSG_RESULT($enable_mixedcase)
273 if test "$enable_mixedcase" = "auto" ; then
274         CF_MIXEDCASE_FILENAMES
275 else
276         cf_cv_mixedcase=$enable_mixedcase
277         if test "x$enable_mixedcase" = "xyes" ; then
278                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
279         fi
280 fi
281
282 # do this after mixed-case option (tags/TAGS is not as important as tic).
283 AC_PROG_MAKE_SET
284 CF_MAKE_TAGS
285 CF_MAKEFLAGS
286
287 dnl These are standard among *NIX systems, but not when cross-compiling
288 AC_CHECK_TOOL(RANLIB, ranlib, ':')
289 AC_CHECK_TOOL(LD, ld, ld)
290 AC_CHECK_TOOL(AR, ar, ar)
291 AC_CHECK_TOOL(NM, nm, nm)
292 CF_AR_FLAGS
293
294 dnl Special option for use by system-builders: the install-prefix is used to
295 dnl adjust the location into which the actual install is done, so that an
296 dnl archive can be built without modifying the host system's configuration.
297 AC_MSG_CHECKING(if you have specified an install-prefix)
298 AC_ARG_WITH(install-prefix,
299         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
300         [case "x$withval" in
301         (xyes|xno)
302                 ;;
303         (*)     DESTDIR="$withval"
304                 ;;
305         esac])
306 AC_MSG_RESULT($DESTDIR)
307 AC_SUBST(DESTDIR)
308
309 ###############################################################################
310 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
311 # If we're cross-compiling, allow the user to override the tools and their
312 # options.  The configure script is oriented toward identifying the host
313 # compiler, etc., but we need a build compiler to generate parts of the source.
314
315 case $cf_cv_system_name in
316 (*-msvc*)
317         LDFLAGS="$LDFLAGS user32.lib"
318         export LDFLAGS
319         ;;
320 esac
321
322 CF_BUILD_CC
323
324 ###############################################################################
325 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
326
327 ### Options to allow the user to specify the set of libraries which are used.
328 ### Use "--without-normal --with-shared" to allow the default model to be
329 ### shared, for example.
330 cf_list_models=""
331 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
332
333 CF_WITH_LIBTOOL
334 if test "$with_libtool" != "no" ; then
335
336 cf_list_models="$cf_list_models libtool"
337
338 else
339
340 AC_MSG_CHECKING(if you want to build shared libraries)
341 AC_ARG_WITH(shared,
342         [  --with-shared           generate shared-libraries],
343         [with_shared=$withval],
344         [with_shared=no])
345 AC_MSG_RESULT($with_shared)
346 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
347
348 AC_MSG_CHECKING(if you want to build static libraries)
349 AC_ARG_WITH(normal,
350         [  --with-normal           generate normal-libraries (default)],
351         [with_normal=$withval],
352         [with_normal=yes])
353 AC_MSG_RESULT($with_normal)
354 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
355
356 AC_MSG_CHECKING(if you want to build debug libraries)
357 AC_ARG_WITH(debug,
358         [  --with-debug            generate debug-libraries (default)],
359         [with_debug=$withval],
360         [with_debug=yes])
361 AC_MSG_RESULT($with_debug)
362 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
363
364 AC_MSG_CHECKING(if you want to build profiling libraries)
365 AC_ARG_WITH(profile,
366         [  --with-profile          generate profile-libraries],
367         [with_profile=$withval],
368         [with_profile=no])
369 AC_MSG_RESULT($with_profile)
370 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
371
372 fi
373
374 if test "X$cf_with_cxx_binding" != Xno; then
375 if test "x$with_shared" = "xyes"; then
376 AC_MSG_CHECKING(if you want to build C++ shared libraries)
377 AC_ARG_WITH(cxx-shared,
378         [  --with-cxx-shared       generate C++ shared-libraries],
379         [with_shared_cxx=$withval],
380         [with_shared_cxx=no])
381 AC_MSG_RESULT($with_shared_cxx)
382 fi
383 fi
384
385 ###############################################################################
386
387 AC_MSG_CHECKING(for specified models)
388 test -z "$cf_list_models" && cf_list_models=normal
389 dnl If we use libtool to generate libraries, then it must be the only
390 dnl specified model.
391 test "$with_libtool" != "no" && cf_list_models=libtool
392 AC_MSG_RESULT($cf_list_models)
393
394 ### Use the first model as the default, and save its suffix for use in building
395 ### up test-applications.
396 AC_MSG_CHECKING(for default model)
397 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
398 AC_MSG_RESULT($DFT_LWR_MODEL)
399
400 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
401
402 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
403 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
404
405 TICS_NAME=tic
406 AC_SUBST(TICS_NAME)
407
408 TINFO_NAME=tinfo
409 AC_SUBST(TINFO_NAME)
410
411 LIB_NAME=ncurses
412 AC_SUBST(LIB_NAME)
413
414 LIB_DIR=../lib
415 LIB_2ND=../../lib
416
417 CF_WITH_LIB_PREFIX(cf_prefix)
418
419 LIB_SUFFIX=
420 AC_SUBST(LIB_SUFFIX)
421 CF_PATHSEP
422
423 ###############################################################################
424
425 AC_MSG_CHECKING(if you want to build a separate terminfo library)
426 AC_ARG_WITH(termlib,
427         [  --with-termlib          generate separate terminfo library],
428         [with_termlib=$withval],
429         [with_termlib=no])
430 AC_MSG_RESULT($with_termlib)
431
432 AC_MSG_CHECKING(if you want to build a separate tic library)
433 AC_ARG_WITH(ticlib,
434         [  --with-ticlib           generate separate tic library],
435         [with_ticlib=$withval],
436         [with_ticlib=no])
437 AC_MSG_RESULT($with_ticlib)
438
439 dnl Not all ports of gcc support the -g option
440
441 if test X"$CC_G_OPT" = X"" ; then
442         CC_G_OPT='-g'
443         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
444 fi
445 AC_SUBST(CC_G_OPT)
446
447 if test X"$CXX_G_OPT" = X"" ; then
448         CXX_G_OPT='-g'
449         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
450 fi
451 AC_SUBST(CXX_G_OPT)
452
453 AC_MSG_CHECKING(for default loader flags)
454 case $DFT_LWR_MODEL in
455 (libtool) LD_MODEL=''   ;;
456 (normal)  LD_MODEL=''   ;;
457 (debug)   LD_MODEL=$CC_G_OPT ;;
458 (profile) LD_MODEL='-pg';;
459 (shared)  LD_MODEL=''   ;;
460 esac
461 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
462 AC_MSG_RESULT($LD_MODEL)
463
464 case $DFT_LWR_MODEL in
465 (shared)
466 CF_ENABLE_RPATH
467 AC_MSG_CHECKING(if shared libraries should be relinked during install)
468 AC_ARG_ENABLE(relink,
469 [  --disable-relink        relink shared libraries during install],
470 [cf_cv_do_relink=$enableval],
471 [cf_cv_do_relink=yes])
472 AC_MSG_RESULT($cf_cv_do_relink)
473         ;;
474 esac
475
476 # we will build libraries one-level down.
477 rel_builddir=..
478 CF_SHARED_OPTS
479 for model in $cf_list_models; do
480         case $model in
481         (libtool)
482                 CF_WITH_LIBTOOL_OPTS
483                 CF_WITH_EXPORT_SYMS
484                 ;;
485         (shared)
486                 if test "$CC_SHARED_OPTS" = "unknown"; then
487                         AC_ERROR(Shared libraries are not supported in this version)
488                 fi
489                 # workaround for inept transition to PIE vs PIC...
490                 AC_MSG_CHECKING(if current CFLAGS link properly)
491                 AC_TRY_LINK(
492                         [#include <stdio.h>],
493                         [printf("Hello work\n");],
494                         [cf_cflags_work=yes],
495                         [cf_cflags_work=no])
496                 AC_MSG_RESULT($cf_cflags_work)
497                 if test "$cf_cflags_work" = no
498                 then
499                         CF_VERBOSE(try to work around by appending shared-options)
500                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
501                 fi
502                 CF_WITH_VERSIONED_SYMS
503                 ;;
504         esac
505 done
506
507 ### Checks for special libraries, must be done up-front.
508 SHLIB_LIST=""
509 CF_WITH_GPM
510 if test "$with_gpm" != no ; then
511         AC_MSG_CHECKING(if you want to load GPM dynamically)
512         AC_ARG_WITH(dlsym,
513                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
514                 [with_dlsym=$withval],
515                 [with_dlsym=yes])
516         AC_MSG_RESULT($with_dlsym)
517         if test "x$with_dlsym" = xyes ; then
518                 CF_FUNC_DLSYM
519                 if test "x$with_gpm" != xyes ; then
520                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
521                         cf_cv_gpm_soname="$with_gpm"
522                 else
523                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
524                 fi
525                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
526                 SHLIB_LIST="-ldl $SHLIB_LIST"
527                 CF_ADD_LIB(dl,PRIVATE_LIBS)
528         else
529                 SHLIB_LIST="-lgpm $SHLIB_LIST"
530                 CF_ADD_LIB(gpm,TEST_LIBS)
531                 CF_ADD_LIB(gpm,PRIVATE_LIBS)
532         fi
533         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
534         CF_CHECK_GPM_WGETCH
535 fi
536
537 CF_WITH_PCRE2
538 CF_WITH_SYSMOUSE
539
540 # pretend that ncurses==ncursesw==ncursest
541 AC_MSG_CHECKING(if you want to disable library suffixes)
542 CF_ARG_DISABLE(lib-suffixes,
543         [  --disable-lib-suffixes  disable library suffixes],
544         [disable_lib_suffixes=yes],
545         [disable_lib_suffixes=no],
546         no)
547 AC_MSG_RESULT($disable_lib_suffixes)
548
549 ### If we're building with rpath, try to link non-standard libs that way too.
550 if test "$DFT_LWR_MODEL" = "shared" && test "x$cf_cv_enable_rpath" != xno; then
551         CF_DISABLE_RPATH_HACK
552 fi
553
554 ### Depending on the system, someone may use rpath to build ncurses but not
555 # want users of the package to rely upon that feature.  Give those people an
556 # option to suppress that detail from EXTRA_LDFLAGS.
557 EXTRA_PKG_LDFLAGS="$EXTRA_LDFLAGS"
558 if test -n "$EXTRA_PKG_LDFLAGS"
559 then
560         AC_MSG_CHECKING(if you want to disable extra LDFLAGS for package-scripts)
561         CF_ARG_DISABLE(pkg-ldflags,
562                 [  --disable-pkg-ldflags   disable extra LDFLAGS for package-scripts],
563                 [disable_pkg_ldflags=yes],
564                 [disable_pkg_ldflags=no],
565                 no)
566         AC_MSG_RESULT($disable_pkg_ldflags)
567         test "$disable_pkg_ldflags" = yes && EXTRA_PKG_LDFLAGS=
568 fi
569 AC_SUBST(EXTRA_PKG_LDFLAGS)
570
571 ###############################################################################
572 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
573
574 ###     use option --with-extra-suffix to append suffix to headers and libraries
575 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
576 EXTRA_SUFFIX=
577 AC_ARG_WITH(extra-suffix,
578         [  --with-extra-suffix=X   append extra suffix to header/library paths],
579         [case x$withval in
580         (no)
581                 ;;
582         (xyes|x)
583                 EXTRA_SUFFIX=$cf_cv_abi_version
584                 ;;
585         (*)
586                 EXTRA_SUFFIX=$withval
587                 ;;
588         esac
589         ])
590 AC_MSG_RESULT($EXTRA_SUFFIX)
591 AC_SUBST(EXTRA_SUFFIX)
592
593 ###     use option --disable-overwrite to leave out the link to -lcurses
594 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
595 AC_ARG_ENABLE(overwrite,
596         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
597         [with_overwrite=$enableval],
598         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
599 AC_MSG_RESULT($with_overwrite)
600
601 AC_MSG_CHECKING(if external terminfo-database is used)
602 AC_ARG_ENABLE(database,
603         [  --disable-database      do not use terminfo, only fallbacks/termcap],
604         [use_database=$enableval],
605         [use_database=yes])
606 AC_MSG_RESULT($use_database)
607
608 case $host_os in
609 (os2*)
610         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
611         ;;
612 (*)
613         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
614         ;;
615 esac
616 AC_SUBST(TERMINFO_SRC)
617
618 NCURSES_USE_DATABASE=0
619 if test "$use_database" != no ; then
620         NCURSES_USE_DATABASE=1
621
622         AC_MSG_CHECKING(which terminfo source-file will be installed)
623         AC_ARG_WITH(database,
624                 [  --with-database=XXX     specify terminfo source to install],
625                 [TERMINFO_SRC=$withval])
626         AC_MSG_RESULT($TERMINFO_SRC)
627
628         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
629         AC_ARG_WITH(hashed-db,
630                 [  --with-hashed-db        specify hashed-database library],,
631                 [with_hashed_db=no])
632         AC_MSG_RESULT($with_hashed_db)
633 else
634         with_hashed_db=no
635 fi
636 AC_SUBST(NCURSES_USE_DATABASE)
637
638 AC_MSG_CHECKING(for list of fallback descriptions)
639 AC_ARG_WITH(fallbacks,
640         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
641         [with_fallback=$withval],
642         [with_fallback=])
643 AC_MSG_RESULT($with_fallback)
644
645 case ".$with_fallback" in
646 (.|.no)
647         FALLBACK_LIST=
648         ;;
649 (.yes)
650         AC_MSG_WARN(expected a list of terminal descriptions)
651         ;;
652 (*)
653         FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
654         ;;
655 esac
656
657 # The fallback feature in ncurses relies upon tic/infocmp outside the build
658 # tree for generating the terminal descriptions that will be compiled into the
659 # library.  If your toolchain is old, it may not handle current terminal
660 # databases.  Use configure-options to point to the tools which will be used,
661 # rather than the first ones found on the $PATH.
662 AC_CHECK_TOOL(TIC, tic)
663 AC_CHECK_TOOL(INFOCMP, infocmp)
664 if test -n "$FALLBACK_LIST"
665 then
666         CF_WITH_PATH_PROG(TIC,     tic,     [for fallbacks], $PATH:/usr/local/ncurses/bin)
667         CF_WITH_PATH_PROG(INFOCMP, infocmp, [for fallbacks], $PATH:/usr/local/ncurses/bin)
668         test -z "$TIC" && FALLBACK_LIST=
669         test -z "$INFOCMP" && FALLBACK_LIST=
670         if test -z "$FALLBACK_LIST"
671         then
672                 AC_MSG_WARN(ignoring fallback option because tic/infocmp are not available)
673         fi
674 fi
675 AC_SUBST(TIC)
676 AC_SUBST(INFOCMP)
677
678 USE_FALLBACKS=
679 test -z "$FALLBACK_LIST" && USE_FALLBACKS="#"
680 AC_SUBST(FALLBACK_LIST)
681 AC_SUBST(USE_FALLBACKS)
682
683 AC_MSG_CHECKING(if you want modern xterm or antique)
684 AC_ARG_WITH(xterm-new,
685         [  --without-xterm-new     specify if xterm terminfo should be old version],
686         [with_xterm_new=$withval],
687         [with_xterm_new=yes])
688 case $with_xterm_new in
689 (no) with_xterm_new=xterm-old;;
690 (*)      with_xterm_new=xterm-new;;
691 esac
692 AC_MSG_RESULT($with_xterm_new)
693 WHICH_XTERM=$with_xterm_new
694 AC_SUBST(WHICH_XTERM)
695
696 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
697 AC_ARG_WITH(xterm-kbs,
698         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
699         [with_xterm_kbs=$withval],
700         [with_xterm_kbs=BS])
701 case x$with_xterm_kbs in
702 (xyes|xno|xBS|xbs|x8)
703         with_xterm_kbs=BS
704         ;;
705 (xDEL|xdel|x127)
706         with_xterm_kbs=DEL
707         ;;
708 (*)
709         with_xterm_kbs=$withval
710         ;;
711 esac
712 AC_MSG_RESULT($with_xterm_kbs)
713 XTERM_KBS=$with_xterm_kbs
714 AC_SUBST(XTERM_KBS)
715
716 MAKE_TERMINFO=
717 if test "$use_database" = no ; then
718         TERMINFO="${datadir}/terminfo"
719         MAKE_TERMINFO="#"
720 else
721
722 AC_MSG_CHECKING(for list of terminfo directories)
723 CF_WITH_PATHLIST(terminfo-dirs,
724         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
725         TERMINFO_DIRS,
726         DATADIR/terminfo,
727         ${datadir}/terminfo)
728 AC_MSG_RESULT($TERMINFO_DIRS)
729 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
730
731 case "x$TERMINFO" in
732 x???:*)
733         AC_MSG_WARN(ignoring non-directory/file TERMINFO value)
734         unset TERMINFO
735         ;;
736 esac
737
738 AC_MSG_CHECKING(for default terminfo directory)
739 CF_WITH_PATH(default-terminfo-dir,
740         [  --with-default-terminfo-dir=DIR default terminfo directory],
741         TERMINFO,
742         DATADIR/terminfo,
743         ${datadir}/terminfo)
744 AC_MSG_RESULT($TERMINFO)
745 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
746
747 fi
748
749 AC_SUBST(TERMINFO)
750 AC_SUBST(MAKE_TERMINFO)
751
752 ###     use option --disable-big-core to make tic run on small machines
753 ###     We need 4Mb, check if we can allocate 50% more than that.
754 AC_MSG_CHECKING(if big-core option selected)
755 AC_ARG_ENABLE(big-core,
756         [  --disable-big-core      assume machine has little memory],
757         [with_big_core=$enableval],
758         [AC_TRY_RUN([
759 #include <stdlib.h>
760 #include <string.h>
761 int main() {
762         unsigned long n = 6000000L;
763         char *s = malloc(n);
764         if (s != 0)
765                 s[0] = s[n-1] = 0;
766         ${cf_cv_main_return:-return}(s == 0);
767 }],
768         [with_big_core=yes],
769         [with_big_core=no],
770         [with_big_core=no])])
771 AC_MSG_RESULT($with_big_core)
772 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
773
774 ### ISO C only guarantees 512-char strings, we have tables which load faster
775 ### when constructed using "big" strings.  More than the C compiler, the awk
776 ### program is a limit on most vendor UNIX systems.  Check that we can build.
777 AC_MSG_CHECKING(if big-strings option selected)
778 AC_ARG_ENABLE(big-strings,
779         [  --disable-big-strings   assume compiler has only standard-size strings],
780         [with_big_strings=$enableval],
781         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
782 AC_MSG_RESULT($with_big_strings)
783
784 USE_BIG_STRINGS=0
785 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
786 AC_SUBST(USE_BIG_STRINGS)
787
788 ###     use option --enable-termcap to compile in the termcap fallback support
789 AC_MSG_CHECKING(if you want termcap-fallback support)
790 AC_ARG_ENABLE(termcap,
791         [  --enable-termcap        compile in termcap fallback support],
792         [with_termcap=$enableval],
793         [with_termcap=no])
794 AC_MSG_RESULT($with_termcap)
795
796 NCURSES_USE_TERMCAP=0
797 if test "x$with_termcap" != "xyes" ; then
798         if test "$use_database" = no ; then
799                 if test -z "$with_fallback" ; then
800                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
801                 fi
802         fi
803         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
804 else
805
806         if test "$with_ticlib" != no ; then
807                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
808         fi
809
810         NCURSES_USE_TERMCAP=1
811         AC_MSG_CHECKING(for list of termcap files)
812         CF_WITH_PATHLIST(termpath,
813                 [  --with-termpath=XXX     specify list of termcap files],
814                 TERMPATH,
815                 /etc/termcap:/usr/share/misc/termcap)
816         AC_MSG_RESULT($TERMPATH)
817         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
818
819         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
820         AC_MSG_CHECKING(if fast termcap-loader is needed)
821         AC_ARG_ENABLE(getcap,
822                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
823                 [with_getcap=$enableval],
824                 [with_getcap=no])
825         AC_MSG_RESULT($with_getcap)
826         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
827
828         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
829         AC_ARG_ENABLE(getcap-cache,
830                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
831                 [with_getcap_cache=$enableval],
832                 [with_getcap_cache=no])
833         AC_MSG_RESULT($with_getcap_cache)
834         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
835
836 fi
837 AC_SUBST(NCURSES_USE_TERMCAP)
838
839 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
840 AC_MSG_CHECKING(if ~/.terminfo is wanted)
841 AC_ARG_ENABLE(home-terminfo,
842         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
843         [with_home_terminfo=$enableval],
844         [with_home_terminfo=yes])
845 AC_MSG_RESULT($with_home_terminfo)
846 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
847
848 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
849 AC_ARG_ENABLE(root-environ,
850         [  --disable-root-environ  restrict environment when running as root],
851         [with_root_environ=$enableval],
852         [with_root_environ=yes])
853 AC_MSG_RESULT($with_root_environ)
854 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
855
856 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
857 ###   to reduce storage requirements for the terminfo database.
858 CF_LINK_FUNCS
859
860 with_links=no
861 with_symlinks=no
862
863 # soft links (symbolic links) are useful for some systems where hard links do
864 # not work, or to make it simpler to copy terminfo trees around.
865 if test "x$ac_cv_func_symlink" = xyes ; then
866         AC_MSG_CHECKING(if tic should use symbolic links)
867         AC_ARG_ENABLE(symlinks,
868         [  --enable-symlinks       make tic use symbolic links not hard links],
869         [with_symlinks=$enableval],
870         [with_symlinks=no])
871         AC_MSG_RESULT($with_symlinks)
872 fi
873
874 # If we have hard links and did not choose to use soft links instead, there is
875 # no reason to make this choice optional - use the hard links.
876 if test "$with_symlinks" = no ; then
877         AC_MSG_CHECKING(if tic should use hard links)
878         if test "x$ac_cv_func_link" = xyes ; then
879                 with_links=yes
880         else
881                 with_links=no
882         fi
883         AC_MSG_RESULT($with_links)
884 fi
885
886 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
887 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
888
889 ###   use option --enable-broken-linker to force on use of broken-linker support
890 CF_ENABLE_BROKEN_LINKER
891
892 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
893 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
894 AC_ARG_ENABLE(bsdpad,
895         [  --enable-bsdpad         recognize BSD-style prefix padding],
896         [with_bsdpad=$enableval],
897         [with_bsdpad=no])
898 AC_MSG_RESULT($with_bsdpad)
899 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
900
901 ###   use option --enable-widec to turn on use of wide-character support
902 NCURSES_CH_T=chtype
903 NCURSES_LIBUTF8=0
904
905 NEED_WCHAR_H=0
906 NCURSES_MBSTATE_T=0
907 NCURSES_WCHAR_T=0
908 NCURSES_WINT_T=0
909
910 # Check to define _XOPEN_SOURCE "automatically"
911 CPPFLAGS_before_XOPEN="$CPPFLAGS"
912 CF_XOPEN_SOURCE(600)
913 CPPFLAGS_after_XOPEN="$CPPFLAGS"
914
915 # Work around breakage on OS X
916 CF_SIGWINCH
917
918 # Checks for CODESET support.
919 AM_LANGINFO_CODESET
920
921 # use these variables to work around a defect in gcc's fixincludes.
922 NCURSES_OK_WCHAR_T=
923 NCURSES_OK_WINT_T=
924
925 AC_MSG_CHECKING(if you want wide-character code)
926 AC_ARG_ENABLE(widec,
927         [  --enable-widec          compile with wide-char/UTF-8 code],
928         [with_widec=$enableval],
929         [with_widec=no])
930 AC_MSG_RESULT($with_widec)
931
932 NCURSES_WCWIDTH_GRAPHICS=1
933 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
934
935 if test "x$with_widec" = xyes ; then
936         if test "x$disable_lib_suffixes" = xno ; then
937                 LIB_SUFFIX="w${LIB_SUFFIX}"
938         fi
939         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
940         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
941
942         CF_CHECK_WCHAR_H
943         CF_CHECK_WCWIDTH_GRAPHICS
944         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
945
946         # with_overwrite=no
947         NCURSES_CH_T=cchar_t
948         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
949         if test "x$ac_cv_func_putwc" != xyes ; then
950                 CF_UTF8_LIB
951                 if test "$cf_cv_utf8_lib" != no ; then
952                         NCURSES_LIBUTF8=1
953                 fi
954         fi
955         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
956         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
957         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
958
959         if test "$NCURSES_MBSTATE_T" != 0; then
960                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
961         fi
962 fi
963 AC_SUBST(NCURSES_CH_T)
964 AC_SUBST(NCURSES_LIBUTF8)
965
966 AC_SUBST(NEED_WCHAR_H)
967 AC_SUBST(NCURSES_MBSTATE_T)
968 AC_SUBST(NCURSES_WCHAR_T)
969 AC_SUBST(NCURSES_WINT_T)
970
971 AC_SUBST(NCURSES_OK_WCHAR_T)
972 AC_SUBST(NCURSES_OK_WINT_T)
973
974 ###   use option --disable-lp64 to allow long chtype
975 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
976 AC_ARG_ENABLE(lp64,
977         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
978         [with_lp64=$enableval],
979         [with_lp64=$cf_dft_with_lp64])
980 AC_MSG_RESULT($with_lp64)
981
982 if test "x$with_lp64" = xyes ; then
983         cf_cv_enable_lp64=1
984 else
985         cf_cv_enable_lp64=0
986 fi
987 AC_SUBST(cf_cv_enable_lp64)
988
989 CF_LARGEFILE
990
991 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
992 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
993 AC_ARG_ENABLE(tparm-varargs,
994         [  --disable-tparm-varargs compile tparm() without varargs interface],
995         [with_tparm_varargs=$enableval],
996         [with_tparm_varargs=yes])
997 AC_MSG_RESULT($with_tparm_varargs)
998 NCURSES_TPARM_VARARGS=0
999 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
1000 AC_SUBST(NCURSES_TPARM_VARARGS)
1001
1002 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
1003 if test "$with_ticlib" != no ; then
1004 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
1005 AC_ARG_ENABLE(tic-depends,
1006         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
1007         [with_tic_depends=$enableval],
1008         [with_tic_depends=yes])
1009 AC_MSG_RESULT($with_tic_depends)
1010 else
1011         with_tic_depends=no
1012 fi
1013
1014 ###   use option --disable-wattr-macros to suppress wattr* macros from curses.h
1015 AC_MSG_CHECKING(if you want to suppress wattr* macros to help with ncurses5/ncurses6 transition)
1016 AC_ARG_ENABLE(wattr-macros,
1017         [  --disable-wattr-macros  suppress wattr* macros to help with ncurses5/ncurses6 transition],
1018         [with_wattr_macros=$enableval],
1019         [with_wattr_macros=yes])
1020 if [[ "x$with_wattr_macros" != xyes ]]; then
1021         NCURSES_WATTR_MACROS=0
1022         AC_MSG_RESULT(yes)
1023 else
1024         NCURSES_WATTR_MACROS=1
1025         AC_MSG_RESULT(no)
1026 fi
1027 AC_SUBST(NCURSES_WATTR_MACROS)
1028
1029 CF_WITH_X11_RGB
1030
1031 ###   use option --with-bool to override bool's type
1032 AC_MSG_CHECKING(for type of bool)
1033 AC_ARG_WITH(bool,
1034         [  --with-bool=TYPE        override fallback type of bool variable],
1035         [NCURSES_BOOL="$withval"],
1036         [NCURSES_BOOL=auto])
1037 AC_MSG_RESULT($NCURSES_BOOL)
1038 AC_SUBST(NCURSES_BOOL)
1039
1040 AC_MSG_CHECKING(for alternate terminal capabilities file)
1041 AC_ARG_WITH(caps,
1042         [  --with-caps=alt         compile with alternate Caps file],
1043         [TERMINFO_CAPS=Caps.$withval],
1044         [TERMINFO_CAPS=Caps])
1045 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
1046 AC_MSG_RESULT($TERMINFO_CAPS)
1047 AC_SUBST(TERMINFO_CAPS)
1048
1049 ###   use option --with-chtype to override chtype's type
1050 AC_MSG_CHECKING(for type of chtype)
1051 AC_ARG_WITH(chtype,
1052         [  --with-chtype=TYPE      override type of chtype],
1053         [NCURSES_CHTYPE="$withval"],
1054         [NCURSES_CHTYPE=$cf_dft_chtype])
1055 AC_MSG_RESULT($NCURSES_CHTYPE)
1056
1057 ###   use option --with-ospeed to override ospeed's type
1058 AC_MSG_CHECKING(for type of ospeed)
1059 AC_ARG_WITH(ospeed,
1060         [  --with-ospeed=TYPE      override type of ospeed variable],
1061         [NCURSES_OSPEED="$withval"],
1062         [NCURSES_OSPEED=short])
1063 AC_MSG_RESULT($NCURSES_OSPEED)
1064 AC_SUBST(NCURSES_OSPEED)
1065
1066 ###   use option --with-mmask-t to override mmask_t's type
1067 AC_MSG_CHECKING(for type of mmask_t)
1068 AC_ARG_WITH(mmask-t,
1069         [  --with-mmask-t=TYPE     override type of mmask_t],
1070         [NCURSES_MMASK_T="$withval"],
1071         [NCURSES_MMASK_T=$cf_dft_mmask_t])
1072 AC_MSG_RESULT($NCURSES_MMASK_T)
1073
1074 ###   use option --with-ccharw-max to override CCHARW_MAX size
1075 AC_MSG_CHECKING(for size CCHARW_MAX)
1076 AC_ARG_WITH(ccharw-max,
1077         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1078         [NCURSES_CCHARW_MAX="$withval"],
1079         [NCURSES_CCHARW_MAX=5])
1080 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1081 AC_SUBST(NCURSES_CCHARW_MAX)
1082
1083 AC_CHECK_SIZEOF([signed char])
1084 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1085         NCURSES_SBOOL="signed char"
1086 else
1087         NCURSES_SBOOL="char"
1088 fi
1089 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1090 AC_ARG_ENABLE(signed-char,
1091         [  --enable-signed-char    compile using signed Boolean's in term.h],
1092         [with_signed_char=$enableval],
1093         [with_signed_char=no])
1094 AC_MSG_RESULT($with_signed_char)
1095 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1096 AC_SUBST(NCURSES_SBOOL)
1097
1098 ###   use option --with-tparm-arg to override tparm's argument type
1099 AC_MSG_CHECKING(for type of tparm args)
1100 AC_ARG_WITH(tparm-arg,
1101         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1102         [NCURSES_TPARM_ARG="$withval"],
1103         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1104 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1105 AC_SUBST(NCURSES_TPARM_ARG)
1106
1107 ### Enable compiling-in rcs id's
1108 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1109 AC_ARG_WITH(rcs-ids,
1110         [  --with-rcs-ids          compile-in RCS identifiers],
1111         [with_rcs_ids=$withval],
1112         [with_rcs_ids=no])
1113 AC_MSG_RESULT($with_rcs_ids)
1114 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1115
1116 ###############################################################################
1117 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1118
1119 ###############################################################################
1120 CF_HELP_MESSAGE(Extensions:)
1121
1122 ### Note that some functions (such as const) are normally disabled anyway.
1123 AC_MSG_CHECKING(if you want to build with function extensions)
1124 AC_ARG_ENABLE(ext-funcs,
1125         [  --disable-ext-funcs     disable function-extensions],
1126         [with_ext_funcs=$enableval],
1127         [with_ext_funcs=yes])
1128 AC_MSG_RESULT($with_ext_funcs)
1129 if test "x$with_ext_funcs" = xyes ; then
1130         NCURSES_EXT_FUNCS=1
1131         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1132         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1133         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1134         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1135         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1136         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1137         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1138         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1139         AC_DEFINE(HAVE_USE_EXTENDED_NAMES,1,[Define to 1 to enable use_extended_names() function in test-programs])
1140         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1141         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1142         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1143         GENERATED_EXT_FUNCS=generated
1144         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1145 else
1146         NCURSES_EXT_FUNCS=0
1147         GENERATED_EXT_FUNCS=
1148 fi
1149 AC_SUBST(NCURSES_EXT_FUNCS)
1150 AC_SUBST(GENERATED_EXT_FUNCS)
1151
1152 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1153 AC_ARG_ENABLE(sp-funcs,
1154         [  --enable-sp-funcs       enable SCREEN-extensions],
1155         [with_sp_funcs=$enableval],
1156         [with_sp_funcs=$cf_dft_ext_spfuncs])
1157 AC_MSG_RESULT($with_sp_funcs)
1158 if test "x$with_sp_funcs" = xyes ; then
1159         NCURSES_SP_FUNCS=1
1160         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1161         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1162         GENERATED_SP_FUNCS=generated
1163 else
1164         NCURSES_SP_FUNCS=0
1165         GENERATED_SP_FUNCS=
1166 fi
1167 AC_SUBST(NCURSES_SP_FUNCS)
1168 AC_SUBST(GENERATED_SP_FUNCS)
1169
1170 AC_MSG_CHECKING(if you want to build with terminal-driver)
1171 AC_ARG_ENABLE(term-driver,
1172         [  --enable-term-driver    enable terminal-driver],
1173         [with_term_driver=$enableval],
1174         [with_term_driver=no])
1175 AC_MSG_RESULT($with_term_driver)
1176 if test "x$with_term_driver" = xyes ; then
1177         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1178         if test "x$with_termlib" != xno ; then
1179                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1180         fi
1181         if test "x$with_sp_funcs" != xyes ; then
1182                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1183         fi
1184 fi
1185
1186 ###   use option --enable-const to turn on use of const beyond that in XSI.
1187 AC_MSG_CHECKING(for extended use of const keyword)
1188 AC_ARG_ENABLE(const,
1189         [  --enable-const          compile with extra/non-standard const],
1190         [with_ext_const=$enableval],
1191         [with_ext_const=$cf_dft_ext_const])
1192 AC_MSG_RESULT($with_ext_const)
1193 NCURSES_CONST='/*nothing*/'
1194 if test "x$with_ext_const" = xyes ; then
1195         NCURSES_CONST=const
1196 fi
1197 AC_SUBST(NCURSES_CONST)
1198
1199 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1200 AC_MSG_CHECKING(if you want to use extended colors)
1201 AC_ARG_ENABLE(ext-colors,
1202         [  --enable-ext-colors     compile for 256-color support],
1203         [with_ext_colors=$enableval],
1204         [with_ext_colors=$cf_dft_ext_colors])
1205 AC_MSG_RESULT($with_ext_colors)
1206 NCURSES_EXT_COLORS=0
1207 if test "x$with_ext_colors" = xyes ; then
1208         if test "x$with_widec" != xyes ; then
1209                 AC_MSG_WARN(This option applies only to wide-character library)
1210         else
1211                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1212                 CF_NCURSES_ABI_6
1213                 NCURSES_EXT_COLORS=1
1214                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1215                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1216                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1217                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1218         fi
1219 fi
1220 AC_SUBST(NCURSES_EXT_COLORS)
1221
1222 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1223 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1224 AC_ARG_ENABLE(ext-mouse,
1225         [  --enable-ext-mouse      compile for extended mouse-encoding],
1226         [with_ext_mouse=$enableval],
1227         [with_ext_mouse=$cf_dft_ext_mouse])
1228 AC_MSG_RESULT($with_ext_mouse)
1229 NCURSES_MOUSE_VERSION=1
1230 if test "x$with_ext_mouse" = xyes ; then
1231         NCURSES_MOUSE_VERSION=2
1232         CF_NCURSES_ABI_6
1233 fi
1234 AC_SUBST(NCURSES_MOUSE_VERSION)
1235
1236 ###   use option --enable-ext-putwin to turn on extended screendumps
1237 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1238 AC_ARG_ENABLE(ext-putwin,
1239         [  --enable-ext-putwin     compile with extended putwin/screendump],
1240         [with_ext_putwin=$enableval],
1241         [with_ext_putwin=$cf_dft_ext_putwin])
1242 AC_MSG_RESULT($with_ext_putwin)
1243 if test "x$with_ext_putwin" = xyes ; then
1244         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1245 fi
1246
1247 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1248 AC_ARG_ENABLE(no-padding,
1249         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1250         [with_no_padding=$enableval],
1251         [with_no_padding=$with_ext_funcs])
1252 AC_MSG_RESULT($with_no_padding)
1253 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1254
1255 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1256 AC_MSG_CHECKING(if you want SIGWINCH handler)
1257 AC_ARG_ENABLE(sigwinch,
1258         [  --enable-sigwinch       compile with SIGWINCH handler],
1259         [with_sigwinch=$enableval],
1260         [with_sigwinch=$with_ext_funcs])
1261 AC_MSG_RESULT($with_sigwinch)
1262 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1263
1264 ###   use option --enable-tcap-names to allow user to define new capabilities
1265 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1266 AC_ARG_ENABLE(tcap-names,
1267         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1268         [with_tcap_names=$enableval],
1269         [with_tcap_names=$with_ext_funcs])
1270 AC_MSG_RESULT($with_tcap_names)
1271 NCURSES_XNAMES=0
1272 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1273 AC_SUBST(NCURSES_XNAMES)
1274
1275 ##############################################################################
1276 CF_HELP_MESSAGE(Reentrant Code:)
1277 CF_WITH_PTHREAD
1278
1279 if test "x$with_pthread" != xno; then
1280         AC_CHECK_FUNC(pthread_kill,[
1281                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1282                 AC_ARG_ENABLE(pthreads-eintr,
1283                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1284                         [use_pthreads_eintr=$enableval],
1285                         [use_pthreads_eintr=no])
1286                 AC_MSG_RESULT($use_pthreads_eintr)
1287                 if test "x$use_pthreads_eintr" = xyes ; then
1288                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1289                 fi])
1290
1291         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1292         AC_ARG_ENABLE(weak-symbols,
1293                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1294                 [use_weak_symbols=$enableval],
1295                 [use_weak_symbols=no])
1296         AC_MSG_RESULT($use_weak_symbols)
1297         if test "x$use_weak_symbols" = xyes ; then
1298                 CF_WEAK_SYMBOLS
1299         else
1300                 cf_cv_weak_symbols=no
1301         fi
1302
1303         if test "x$cf_cv_weak_symbols" = xyes ; then
1304                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1305         fi
1306 fi
1307
1308 PTHREAD=
1309 if test "x$with_pthread" = "xyes" ; then
1310         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1311         enable_reentrant=yes
1312         if test "x$cf_cv_weak_symbols" = xyes ; then
1313                 PTHREAD=-lpthread
1314                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1315         fi
1316 fi
1317 AC_SUBST(PTHREAD)
1318
1319 # Reentrant code has to be opaque; there's little advantage to making ncurses
1320 # opaque outside of that, so there is no --enable-opaque option.  We can use
1321 # this option without --with-pthreads, but this will be always set for
1322 # pthreads.
1323 AC_MSG_CHECKING(if you want reentrant code)
1324 AC_ARG_ENABLE(reentrant,
1325         [  --enable-reentrant      compile with reentrant code],
1326         [with_reentrant=$enableval],
1327         [with_reentrant=no])
1328 AC_MSG_RESULT($with_reentrant)
1329 if test "x$with_reentrant" = xyes ; then
1330         cf_cv_enable_reentrant=1
1331         cf_cv_enable_opaque="NCURSES_INTERNALS"
1332         NCURSES_SIZE_T=int
1333         if test "x$cf_cv_weak_symbols" = xyes ; then
1334                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1335                 CF_ADD_LIB(pthread,TEST_LIBS)
1336                 CF_ADD_LIB(pthread,TEST_LIBS2)
1337                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1338         else
1339                 # when not using weak symbols but with_reentrant,
1340                 # add 't' to the library suffix on all platforms
1341                 # except cygwin, where we only do that if ALSO
1342                 # compiling with full thread support.
1343                 case "$host" in
1344                 (*cygwin* | *msys*)
1345                         if test "$with_pthread" = "yes" ; then
1346                                 if test "x$disable_lib_suffixes" = "xno" ; then
1347                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1348                                 fi
1349                         fi ;;
1350                 (*)
1351                         if test "x$disable_lib_suffixes" = "xno" ; then
1352                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1353                         fi
1354                         ;;
1355                 esac
1356         fi
1357         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1358         CF_NCURSES_ABI_6
1359 else
1360         cf_cv_enable_reentrant=0
1361         cf_cv_enable_opaque="NCURSES_OPAQUE"
1362         NCURSES_SIZE_T=short
1363 fi
1364 AC_SUBST(cf_cv_enable_reentrant)
1365 AC_SUBST(cf_cv_enable_opaque)
1366
1367 AC_SUBST(NCURSES_SIZE_T)
1368
1369 AC_MSG_CHECKING(if you want opaque curses-library structures)
1370 CF_ARG_ENABLE(opaque-curses,
1371         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1372         [enable_opaque_curses=yes],[
1373          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1374          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=no
1375         ])
1376 AC_MSG_RESULT($enable_opaque_curses)
1377
1378 test "$cf_cv_enable_reentrant" = 1 && \
1379 test "$enable_opaque_curses" = no && \
1380 AC_MSG_ERROR(reentrant configuration requires opaque library)
1381
1382 AC_MSG_CHECKING(if you want opaque form-library structures)
1383 AC_ARG_ENABLE(opaque-form,
1384         [  --enable-opaque-form    make form-library structures "opaque"],
1385         [enable_opaque_form=yes],[enable_opaque_form=no])
1386 AC_MSG_RESULT($enable_opaque_form)
1387
1388 AC_MSG_CHECKING(if you want opaque menu-library structures)
1389 AC_ARG_ENABLE(opaque-menu,
1390         [  --enable-opaque-menu    make menu-library structures "opaque"],
1391         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1392 AC_MSG_RESULT($enable_opaque_menu)
1393
1394 AC_MSG_CHECKING(if you want opaque panel-library structures)
1395 AC_ARG_ENABLE(opaque-panel,
1396         [  --enable-opaque-panel   make panel-library structures "opaque"],
1397         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1398 AC_MSG_RESULT($enable_opaque_panel)
1399
1400 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1401 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1402 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1403 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1404
1405 AC_SUBST(NCURSES_OPAQUE)
1406 AC_SUBST(NCURSES_OPAQUE_FORM)
1407 AC_SUBST(NCURSES_OPAQUE_MENU)
1408 AC_SUBST(NCURSES_OPAQUE_PANEL)
1409
1410 ### Allow using a different wrap-prefix
1411 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1412         AC_MSG_CHECKING(for prefix used to wrap public variables)
1413         AC_ARG_WITH(wrap-prefix,
1414                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1415                 [NCURSES_WRAP_PREFIX=$withval],
1416                 [NCURSES_WRAP_PREFIX=_nc_])
1417         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1418 else
1419         NCURSES_WRAP_PREFIX=_nc_
1420 fi
1421 AC_SUBST(NCURSES_WRAP_PREFIX)
1422 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1423
1424 ###############################################################################
1425 # These options are relatively safe to experiment with.
1426 CF_HELP_MESSAGE(Development Code:)
1427 AC_MSG_CHECKING(if you want all development code)
1428 AC_ARG_WITH(develop,
1429         [  --without-develop       disable development options],
1430         [with_develop=$withval],
1431         [with_develop=no])
1432 AC_MSG_RESULT($with_develop)
1433
1434 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1435 AC_MSG_CHECKING(if you want hard-tabs code)
1436 AC_ARG_ENABLE(hard-tabs,
1437         [  --enable-hard-tabs      compile with hard-tabs code],,
1438         [enable_hard_tabs=$with_develop])
1439 AC_MSG_RESULT($enable_hard_tabs)
1440 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1441
1442 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1443 AC_MSG_CHECKING(if you want limited support for xmc)
1444 AC_ARG_ENABLE(xmc-glitch,
1445         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1446         [enable_xmc_glitch=$with_develop])
1447 AC_MSG_RESULT($enable_xmc_glitch)
1448 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1449
1450 ###############################################################################
1451 # These are just experimental, probably should not be in a package:
1452 CF_HELP_MESSAGE(Experimental Code:)
1453
1454 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1455 AC_ARG_ENABLE(assumed-color,
1456         [  --disable-assumed-color do not assume anything about default-colors],
1457         [with_assumed_color=$enableval],
1458         [with_assumed_color=yes])
1459 AC_MSG_RESULT($with_assumed_color)
1460 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1461
1462 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1463 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1464 AC_ARG_ENABLE(hashmap,
1465         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1466         [with_hashmap=$enableval],
1467         [with_hashmap=yes])
1468 AC_MSG_RESULT($with_hashmap)
1469 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1470
1471 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1472 AC_MSG_CHECKING(if you want colorfgbg code)
1473 AC_ARG_ENABLE(colorfgbg,
1474         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1475         [with_colorfgbg=$enableval],
1476         [with_colorfgbg=no])
1477 AC_MSG_RESULT($with_colorfgbg)
1478 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1479
1480 ###   use option --enable-fvisibility to turn on use of gcc-specific feature
1481 AC_MSG_CHECKING(if you want to use gcc -fvisibility option)
1482 AC_ARG_ENABLE(fvisibility,
1483         [  --enable-fvisibility    compile with -fvisibility=hidden],
1484         [cf_with_fvisibility=$enableval],
1485         [cf_with_fvisibility=no])
1486 AC_MSG_RESULT($cf_with_fvisibility)
1487
1488 NCURSES_IMPEXP=
1489 NCURSES_CXX_IMPEXP=
1490 if test "x$cf_with_fvisibility" = xyes; then
1491         CF_CHECK_FVISIBILITY($CC,CFLAGS,cf_cv_fvisibility_hidden)
1492         if test "x$cf_cv_fvisibility_hidden" = xyes
1493         then
1494                 CF_ADD_CFLAGS([-fvisibility=hidden])
1495                 NCURSES_IMPEXP="__attribute__ ((visibility(\"default\")))"
1496         fi
1497         if test -n "$CXX"
1498         then
1499                 AC_LANG_PUSH(C++)
1500                 CF_CHECK_FVISIBILITY($CXX,CXXFLAGS,cf_cv_fvisibility_hidden2)
1501                 if test "x$cf_cv_fvisibility_hidden2" = xyes
1502                 then
1503                         CF_ADD_CXXFLAGS([-fvisibility=hidden])
1504                         NCURSES_CXX_IMPEXP="__attribute__ ((visibility(\"default\")))"
1505                 fi
1506                 AC_LANG_POP
1507         fi
1508 fi
1509 AC_SUBST(NCURSES_IMPEXP)
1510 AC_SUBST(NCURSES_CXX_IMPEXP)
1511
1512 ###   use option --enable-interop to turn on use of bindings used for interop
1513 AC_MSG_CHECKING(if you want interop bindings)
1514 AC_ARG_ENABLE(interop,
1515         [  --enable-interop        compile-in interop bindings],
1516         [with_exp_interop=$enableval],
1517         [with_exp_interop=$cf_dft_interop])
1518 AC_MSG_RESULT($with_exp_interop)
1519
1520 NCURSES_INTEROP_FUNCS=0
1521 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1522 AC_SUBST(NCURSES_INTEROP_FUNCS)
1523
1524
1525 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1526 AC_ARG_ENABLE(safe-sprintf,
1527         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1528         [with_safe_sprintf=$enableval],
1529         [with_safe_sprintf=no])
1530 AC_MSG_RESULT($with_safe_sprintf)
1531
1532 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1533 # when hashmap is used scroll hints are useless
1534 if test "$with_hashmap" = no ; then
1535 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1536 AC_ARG_ENABLE(scroll-hints,
1537         [  --disable-scroll-hints  compile without scroll-hints code],
1538         [with_scroll_hints=$enableval],
1539         [with_scroll_hints=yes])
1540 AC_MSG_RESULT($with_scroll_hints)
1541 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1542 fi
1543
1544 AC_MSG_CHECKING(if you want wgetch-events code)
1545 AC_ARG_ENABLE(wgetch-events,
1546         [  --enable-wgetch-events  compile with wgetch-events code],
1547         [with_wgetch_events=$enableval],
1548         [with_wgetch_events=no])
1549 AC_MSG_RESULT($with_wgetch_events)
1550 test "x$with_wgetch_events" = xyes && AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1551
1552 case $cf_cv_system_name in
1553 (*mingw32*|*mingw64*|*-msvc*)
1554         AC_MSG_CHECKING(if you want experimental-Windows driver)
1555         AC_ARG_ENABLE(exp-win32,
1556                 [  --enable-exp-win32      compile with experimental-Windows],
1557                 [with_exp_win32=$enableval],
1558                 [with_exp_win32=no])
1559         AC_MSG_RESULT($with_exp_win32)
1560         test "x$with_exp_win32" = xyes && AC_DEFINE(EXP_WIN32_DRIVER,1,[Define to 1 to compile with experimental win32 driver])
1561         ;;
1562 esac
1563
1564 ###############################################################################
1565 CF_HELP_MESSAGE(Testing/development Options:)
1566
1567 ###     use option --disable-echo to suppress full display compiling commands
1568 CF_DISABLE_ECHO
1569 if test "x$enable_echo" = xyes; then
1570         ECHO_LINK=
1571 else
1572         ECHO_LINK='@ echo linking $@ ... ;'
1573         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1574         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1575 fi
1576 AC_SUBST(ECHO_LINK)
1577
1578 # --disable-stripping is used for debugging
1579 CF_INSTALL_OPTS
1580
1581 # If we're avoiding relinking of shared libraries during install, that is to
1582 # avoid modifying the build-tree.  For the same reason, avoid doing ranlib if
1583 # the install program has "-p" (for preserving timestamps).
1584 cf_cv_do_reranlib=yes
1585 if test "x$cf_cv_install_p" = xyes
1586 then
1587         if test "x$cf_cv_do_relink" != xyes
1588         then
1589                 cf_cv_do_reranlib=no
1590                 INSTALL_OPT_P="-p"
1591                 INSTALL_LIB="$INSTALL_LIB $INSTALL_OPT_P"
1592         fi
1593 fi
1594 AC_SUBST(INSTALL_OPT_P)
1595
1596 ###     use option --enable-warnings to turn on all gcc warnings
1597 CF_ENABLE_WARNINGS(Wno-unknown-pragmas Wswitch-enum,yes)
1598
1599 if test "x$with_warnings" = "xyes"; then
1600         CF_ADD_ADAFLAGS(-gnatg)
1601         if test "x$cf_with_cxx" = xyes ; then
1602                 CF_GXX_WARNINGS(Wno-unused)
1603         fi
1604 fi
1605 CF_ENABLE_STRING_HACKS
1606
1607 ###     use option --enable-assertions to turn on generation of assertion code
1608 AC_MSG_CHECKING(if you want to enable runtime assertions)
1609 AC_ARG_ENABLE(assertions,
1610         [  --enable-assertions     test: turn on generation of assertion code],
1611         [with_assertions=$enableval],
1612         [with_assertions=no])
1613 AC_MSG_RESULT($with_assertions)
1614 if test -n "$GCC"
1615 then
1616         if test "$with_assertions" = no
1617         then
1618                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1619         else
1620                 CF_ADD_ADAFLAGS(-gnata)
1621         fi
1622 fi
1623
1624 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1625 CF_DISABLE_LEAKS
1626 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1627
1628 ###     use option --enable-expanded to generate certain macros as functions
1629 AC_ARG_ENABLE(expanded,
1630         [  --enable-expanded       test: generate functions for certain macros],
1631         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1632
1633 ###     use option --disable-macros to suppress macros in favor of functions
1634 AC_ARG_ENABLE(macros,
1635         [  --disable-macros        test: use functions rather than macros],
1636         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1637
1638 # Normally we only add trace() to the debug-library.  Allow this to be
1639 # extended to all models of the ncurses library:
1640 cf_all_traces=no
1641 case "$CFLAGS $CPPFLAGS" in
1642 (*-DTRACE*)
1643         cf_all_traces=yes
1644         ;;
1645 esac
1646
1647 AC_MSG_CHECKING(whether to add trace feature to all models)
1648 AC_ARG_WITH(trace,
1649 [  --with-trace            test: add trace() function to all models of ncurses],
1650 [cf_with_trace=$withval],
1651 [cf_with_trace=$cf_all_traces])
1652 AC_MSG_RESULT($cf_with_trace)
1653
1654 if test "x$cf_with_trace" = xyes ; then
1655         LIB_TRACING=all
1656         ADA_TRACE=TRUE
1657         CF_ADD_CFLAGS(-DTRACE)
1658         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1659 else
1660         LIB_TRACING=DEBUG
1661         ADA_TRACE=FALSE
1662 fi
1663
1664 AC_SUBST(ADA_TRACE)
1665
1666 CF_DISABLE_GNAT_PROJECTS
1667
1668 ###     Checks for libraries.
1669 case $cf_cv_system_name in
1670 (*mingw32*|*mingw64*)
1671         if test "x$with_exp_win32" = xyes ; then
1672         CPPFLAGS="$CPPFLAGS -DWINVER=0x0600 -DWIN32_LEAN_AND_MEAN"
1673         else
1674         CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1675         fi
1676         # Note: WINVER may be a problem with Windows 10
1677         ;;
1678 (*)
1679 AC_CHECK_FUNC(gettimeofday,
1680         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1681
1682 AC_CHECK_LIB(bsd, gettimeofday,
1683         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1684         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1685         ;;
1686 esac
1687
1688 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1689 AC_SUBST(MATH_LIB)
1690
1691 ###     Checks for header files.
1692 AC_STDC_HEADERS
1693 AC_HEADER_DIRENT
1694 AC_HEADER_TIME
1695 CF_REGEX
1696
1697 dnl These are some other potentially nonportable headers.
1698 AC_CHECK_HEADERS( \
1699 fcntl.h \
1700 getopt.h \
1701 limits.h \
1702 locale.h \
1703 math.h \
1704 poll.h \
1705 sys/ioctl.h \
1706 sys/param.h \
1707 sys/poll.h \
1708 sys/select.h \
1709 sys/time.h \
1710 sys/times.h \
1711 ttyent.h \
1712 unistd.h \
1713 wctype.h \
1714 )
1715
1716 CF_GETOPT_HEADER
1717
1718 CF_CHECK_ENVIRON(environ)
1719 CF_CHECK_GETENV
1720 if test "x$cf_cv_consistent_getenv" = xno && \
1721         test "x$cf_with_trace" = xyes
1722 then
1723         AC_MSG_WARN(The NCURSES_TRACE environment variable is not supported with this configuration)
1724 fi
1725
1726 CF_SYS_TIME_SELECT
1727
1728 ###     checks for compiler characteristics
1729 AC_LANG_C
1730 AC_C_CONST
1731 CF_C_INLINE(NCURSES_INLINE,1200)
1732 CF_SIG_ATOMIC_T
1733
1734 if test $NCURSES_CHTYPE = auto ; then
1735         CF_TYPEOF_CHTYPE
1736 else
1737         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1738 fi
1739 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1740 AC_SUBST(cf_cv_typeof_chtype)
1741
1742 CF_UNSIGNED_LITERALS
1743 cf_cv_1UL="1"
1744 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1745 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1746 AC_SUBST(cf_cv_1UL)
1747
1748 if test $NCURSES_MMASK_T = auto ; then
1749         cf_cv_typeof_mmask_t=long
1750 else
1751         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1752 fi
1753 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1754 AC_SUBST(cf_cv_typeof_mmask_t)
1755
1756 ###     Checks for external-data
1757 CF_ERRNO
1758 CF_LINK_DATAONLY
1759
1760 ###     Checks for library functions.
1761 AC_CHECK_FUNCS( \
1762 getcwd \
1763 getegid \
1764 geteuid \
1765 getopt \
1766 getttynam \
1767 issetugid \
1768 localeconv \
1769 poll \
1770 putenv \
1771 remove \
1772 select \
1773 setbuf \
1774 setbuffer \
1775 setenv \
1776 setvbuf \
1777 sigaction \
1778 sigvec \
1779 snprintf \
1780 strdup \
1781 strstr \
1782 sysconf \
1783 tcgetpgrp \
1784 times \
1785 tsearch \
1786 vsnprintf \
1787 )
1788
1789 if test "x$ac_cv_func_getopt" = xno && \
1790    test "x$cf_with_progs$cf_with_tests" != xnono; then
1791         AC_MSG_ERROR(getopt is required for building programs)
1792 fi
1793
1794 if test "x$with_safe_sprintf" = xyes
1795 then
1796         if test "x$ac_cv_func_vsnprintf" = xyes
1797         then
1798                 AC_MSG_WARN(will use vsnprintf instead of safe-sprintf option)
1799         else
1800                 AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1801         fi
1802 fi
1803
1804 if test "x$with_getcap" = "xyes" ; then
1805         CF_CGETENT
1806 fi
1807
1808 CF_ISASCII
1809 CF_STRUCT_SIGACTION
1810 CF_FUNC_NANOSLEEP
1811 CF_FUNC_TERMIOS
1812 CF_FUNC_VSSCANF
1813 CF_MKSTEMP
1814
1815 # setup for prototype of fallback for vsscanf()
1816 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1817
1818 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1819 if test "x$cross_compiling" = xyes ; then
1820         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1821 else
1822         AC_FUNC_SETVBUF_REVERSED
1823 fi
1824 AC_CHECK_TYPE(intptr_t, long)
1825 AC_CHECK_TYPE(ssize_t, int)
1826 CF_TYPE_SIGACTION
1827 CF_SIZECHANGE
1828 CF_FUNC_MEMMOVE
1829 CF_FUNC_POLL
1830 CF_VA_COPY
1831 AC_FUNC_VFORK
1832 CF_FOPEN_BIN_R
1833
1834 # special check for test/ditto.c
1835 CF_FUNC_OPENPTY
1836 if test "$cf_cv_func_openpty" != no ; then
1837         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1838         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1839         if test "x$cf_cv_lib_util" = xyes ; then
1840                 CF_ADD_LIB(util,TEST_LIBS)
1841         fi
1842 fi
1843 AC_SUBST(TEST_LIBS)
1844 AC_SUBST(TEST_LIBS2)
1845
1846 if test "$with_hashed_db" != no ; then
1847         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1848         CF_HASHED_DB($with_hashed_db)
1849 fi
1850
1851 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1852 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1853         CF_STRIP_G_OPT(CFLAGS)
1854         CF_STRIP_G_OPT(CXXFLAGS)
1855 fi
1856
1857 # Just in case, check if the C compiler has a bool type.
1858 CF_BOOL_DECL(cf_cv_cc_bool_type)
1859
1860 # Check for C++ compiler characteristics (and ensure that it's there!)
1861 if test -n "$CXX" ; then
1862         AC_LANG_CPLUSPLUS
1863         CF_STDCPP_LIBRARY
1864         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1865
1866         case $GXX_VERSION in
1867         (1.*|2.[[0-6]]*|[[1-9]][[0-9]].*)
1868                 cf_cxx_library=yes
1869                 ;;
1870         (*-2.7*|2.7*)
1871                 CF_GPP_LIBRARY
1872                 ;;
1873         (*)
1874                 cf_cxx_library=no
1875                 ;;
1876         esac
1877
1878         AC_CHECK_HEADERS(typeinfo)
1879         CF_CXX_IOSTREAM_NAMESPACE
1880         CF_BOOL_DECL
1881         CF_BOOL_SIZE
1882         CF_ETIP_DEFINES
1883         CF_CPP_PARAM_INIT
1884         CF_CPP_STATIC_CAST
1885         CF_CXX_AR_FLAGS
1886 else
1887         cf_cxx_library=no
1888         cf_cv_builtin_bool=1
1889
1890         # Just because we are not configuring against C++ right now does not
1891         # mean that a user will not want to use C++.  Some distributors disable
1892         # the C++ portion of this configuration as a shortcut (or just to avoid
1893         # compiling the demo in the c++ directory).  So we need a reasonable
1894         # default for the 'bool' type.
1895         #
1896         # Caveat: since the storage of the bool type is not standardized, it
1897         # may change.
1898
1899         if test "$NCURSES_BOOL" != auto ; then
1900                 cf_cv_type_of_bool=$NCURSES_BOOL
1901                 cf_cv_header_stdbool_h=0
1902         else
1903                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1904                         CF_BOOL_SIZE
1905                 else
1906                         AC_MSG_CHECKING(for fallback type of bool)
1907                         case "$host_cpu" in
1908                         (i?86)  cf_cv_type_of_bool=char ;;
1909                         (*)     cf_cv_type_of_bool=int  ;;
1910                         esac
1911                         AC_MSG_RESULT($cf_cv_type_of_bool)
1912                 fi
1913         fi
1914 fi
1915 AC_SUBST(CXXLIBS)
1916
1917 # If the C compiler did not declare bool, and we did not determine that the C++
1918 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1919 # ncurses library use the same type as C++ bool.  Note that this allows one to
1920 # specify the type of bool in a configure-script option and postpone
1921 # integration with the C++ compiler provided that the types are compatible.
1922 USE_CXX_BOOL=1
1923 if test $cf_cv_cc_bool_type = 1
1924 then
1925         # oops: C has a bool.  Unlikely, but C++ could differ.
1926         USE_CXX_BOOL=0
1927 elif test $cf_cv_builtin_bool = 0
1928 then
1929         # C++ has no bool
1930         USE_CXX_BOOL=0
1931 else
1932         # this is the normal case
1933         USE_CXX_BOOL='defined(__cplusplus)'
1934 fi
1935 AC_SUBST(USE_CXX_BOOL)
1936
1937 CF_HELP_MESSAGE(Ada Binding Options:)
1938
1939 dnl If the Ada95 source-tree is present, add that to the build unless it will
1940 dnl not work, or was not requested.
1941 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1942
1943 dnl libtool does not know anything about GNAT, though a change made in 1998
1944 dnl provided for it "someday".  Disable the ada subtree if we are using
1945 dnl libtool -TD 20070714
1946         if test "$cf_with_ada" != "no" ; then
1947                 if test "$with_libtool" != "no"; then
1948                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1949                         cf_with_ada=no
1950                 fi
1951         fi
1952
1953 dnl Check for availability of GNU Ada Translator (GNAT).
1954 dnl At the moment we support no other Ada compiler.
1955         if test "$cf_with_ada" != "no" ; then
1956                 CF_PROG_GNAT
1957                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1958                         CF_ADD_ADAFLAGS(-gnatpn)
1959                         CF_FIXUP_ADAFLAGS
1960
1961                         CF_GNATPREP_OPT_T
1962
1963                         CF_GNAT_GENERICS
1964                         CF_GNAT_SIGINT
1965                         CF_GNAT_PROJECTS
1966
1967                         CF_WITH_ADA_COMPILER
1968
1969                         cf_ada_package=terminal_interface
1970                         AC_SUBST(cf_ada_package)
1971
1972                         CF_WITH_ADA_INCLUDE
1973                         CF_WITH_ADA_OBJECTS
1974                         CF_WITH_ADA_SHAREDLIB
1975
1976                         # allow the Ada binding to be renamed
1977                         CF_WITH_ADA_LIBNAME(AdaCurses)
1978                 fi
1979         fi
1980 else
1981         cf_with_ada=no
1982 fi
1983
1984 # do this "late" to avoid conflict with header-checks
1985 if test "x$with_widec" = xyes ; then
1986         AC_CHECK_SIZEOF(wchar_t)
1987         # cross-compiling to mingw can run into the problem that attempting to
1988         # link with the regex library fails, causing the test to not set this to
1989         # a number.  "recent" autoconf does not address this problem either -TD
1990         if test -z "$ac_cv_sizeof_wchar_t"
1991         then
1992                 CF_VERBOSE(test failed (assume 2))
1993                 sed /SIZEOF_WCHAR_T/d confdefs.h >confdefs.tmp
1994                 mv confdefs.tmp confdefs.h
1995                 echo "#define SIZEOF_WCHAR_T 2" >>confdefs.h
1996         fi
1997 fi
1998
1999 ### Construct the ncurses library-subsets, if any, from this set of keywords:
2000 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
2001 ###
2002 ### ticlib modules may be a separate library, otherwise contained in termlib.
2003 ### termlib modules may be a separate library, otherwise contained in ncurses.
2004 ###
2005 ### The of "+" or " " between the tokens controls the way the script
2006 ### chooses to split module lists into libraries.
2007 ###
2008 ### (see CF_LIB_RULES).
2009 AC_MSG_CHECKING(for library subsets)
2010 LIB_SUBSETS=
2011
2012 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
2013         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
2014         if test "$with_ticlib" != no ; then
2015                 LIB_SUBSETS="${LIB_SUBSETS} "
2016         else
2017                 LIB_SUBSETS="${LIB_SUBSETS}+"
2018         fi
2019 fi
2020
2021 LIB_SUBSETS="${LIB_SUBSETS}termlib"
2022 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
2023
2024 if test "$with_termlib" != no ; then
2025         LIB_SUBSETS="${LIB_SUBSETS} "
2026 else
2027         LIB_SUBSETS="${LIB_SUBSETS}+"
2028 fi
2029
2030 LIB_SUBSETS="${LIB_SUBSETS}base"
2031
2032 # Most term-driver calls are to tinfo, but some like init_pair are to the
2033 # base library (so it resides in base).
2034 if test "$with_term_driver" != no ; then
2035         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
2036         case $cf_cv_system_name in
2037         (*mingw32*|*mingw64*)
2038                 if test "x$with_exp_win32" = xyes ; then
2039                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32"
2040                 else
2041                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
2042                 fi
2043                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
2044                 ;;
2045         (*)
2046                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
2047                 ;;
2048         esac
2049 elif test "x$with_exp_win32" = xyes ; then
2050         case $cf_cv_system_name in
2051         (*mingw32*|*mingw64*)
2052                 LIB_SUBSETS="${LIB_SUBSETS}+port_win32"
2053                 ;;
2054         (*)
2055                 ;;
2056         esac
2057 fi
2058
2059 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
2060 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
2061
2062 AC_MSG_RESULT($LIB_SUBSETS)
2063
2064 ### Construct the list of include-directories to be generated
2065 CF_INCLUDE_DIRS
2066 CF_ADA_INCLUDE_DIRS
2067
2068 ### Build up pieces for makefile rules
2069 AC_MSG_CHECKING(default library suffix)
2070 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
2071 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
2072 AC_MSG_RESULT($DFT_ARG_SUFFIX)
2073
2074 AC_MSG_CHECKING(default library-dependency suffix)
2075 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
2076 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
2077 AC_MSG_RESULT($DFT_DEP_SUFFIX)
2078
2079 AC_MSG_CHECKING(default object directory)
2080 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
2081 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
2082 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
2083
2084 if test "x$cf_with_cxx" = xyes ; then
2085 AC_MSG_CHECKING(c++ library-dependency suffix)
2086 if test "$with_libtool" != "no"; then
2087         # libtool thinks it can make c++ shared libraries (perhaps only g++)
2088         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2089 elif test "$with_shared_cxx" != "no"; then
2090         # also for g++ users...
2091         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2092 else
2093         # we normally make a static library because C/C++ library rules differ
2094         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
2095 fi
2096 AC_MSG_RESULT($CXX_LIB_SUFFIX)
2097 AC_SUBST(CXX_LIB_SUFFIX)
2098 fi
2099
2100 # do not want -ldl in build except as needed for -lncurses dependency
2101 if test "x$with_dlsym" = xyes ; then
2102 if test $DFT_LWR_MODEL = shared || \
2103    test $DFT_LWR_MODEL = libtool ; then
2104         CF_REMOVE_LIB(LIBS,$LIBS,dl)
2105 fi
2106 fi
2107 ### Set up low-level terminfo dependencies for makefiles.
2108
2109 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
2110 # do not need libdl
2111 TICS_LIST=
2112 if test "x$with_dlsym" = xyes ; then
2113         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
2114 fi
2115
2116 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
2117 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
2118 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
2119 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
2120 then
2121         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
2122 fi
2123 AC_SUBST(USE_ARG_SUFFIX)
2124 AC_SUBST(USE_CFG_SUFFIX)
2125 AC_SUBST(USE_LIB_SUFFIX)
2126
2127 if test "$with_ticlib" != no ; then
2128
2129         if test "x$with_ticlib" != xyes ; then
2130                 TICS_NAME=$with_ticlib
2131                 TICS_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
2132                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2133                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2134                 TICS_LIB_SUFFIX="${with_ticlib}"
2135         else
2136                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
2137                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
2138                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
2139                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
2140         fi
2141         TICS_LDFLAGS="-L${LIB_DIR}"
2142         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
2143 else
2144         TICS_SUFFIX=${DFT_LIB_SUFFIX}
2145         TICS_LDFLAGS="-L${LIB_DIR}"
2146         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2147 fi
2148 AC_SUBST(TICS_ARG_SUFFIX)
2149 AC_SUBST(TICS_DEP_SUFFIX)
2150 AC_SUBST(TICS_LIB_SUFFIX)
2151 AC_SUBST(TICS_LDFLAGS)
2152 AC_SUBST(TICS_LIBS)
2153
2154 if test "$with_termlib" != no ; then
2155
2156         if test "x$with_termlib" != xyes ; then
2157                 TINFO_NAME=$with_termlib
2158                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
2159                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2160                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2161                 TINFO_LIB_SUFFIX="${with_termlib}"
2162         else
2163                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2164                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2165                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2166                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2167         fi
2168
2169         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2170         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2171         if test "$DFT_LWR_MODEL" = "libtool"; then
2172                 TEST_ARGS="${TEST_DEPS}"
2173                 TEST_ARG2="${TEST_DEP2}"
2174                 TINFO_LDFLAGS="-L${LIB_DIR}"
2175                 TINFO_LIBS="$TEST_ARGS"
2176                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2177                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2178         else
2179                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2180                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2181                 if test "x$with_term_driver" != xno ; then
2182                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2183                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2184                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2185                 else
2186                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2187                         TINFO_LIBS="$TEST_ARGS"
2188                 fi
2189                 TINFO_LDFLAGS="-L${LIB_DIR}"
2190                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2191         fi
2192 else
2193         # the next lines are needed for linking libtic over libncurses
2194         TINFO_NAME=${LIB_NAME}
2195         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2196         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2197         if test "x$with_tic_depends" = xyes ; then
2198                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2199         else
2200                 TICS_LIST="$SHLIB_LIST"
2201         fi
2202
2203         TINFO_LDFLAGS="-L${LIB_DIR}"
2204         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2205 fi
2206
2207 if test "$DFT_LWR_MODEL" = shared ; then
2208         case $cf_cv_system_name in
2209         (cygwin*|msys*)
2210                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2211                 TINFO_SUFFIX=.dll
2212                 ;;
2213         esac
2214 fi
2215
2216 AC_SUBST(TINFO_ARG_SUFFIX)
2217 AC_SUBST(TINFO_DEP_SUFFIX)
2218 AC_SUBST(TINFO_LIB_SUFFIX)
2219 AC_SUBST(TINFO_LDFLAGS)
2220 AC_SUBST(TINFO_LIBS)
2221
2222 if test "x$with_dlsym" = xyes ; then
2223         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2224 fi
2225
2226 if test "$DFT_LWR_MODEL" = "libtool"; then
2227         OBJEXT=lo
2228 fi
2229
2230 # needed for Ada95
2231 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2232 AC_SUBST(TINFO_LDFLAGS2)
2233
2234 case $DFT_LWR_MODEL in
2235 (normal|debug|profile)
2236         CF_LDFLAGS_STATIC
2237         ;;
2238 esac
2239
2240 AC_MSG_CHECKING(where we will install curses.h)
2241 AC_SUBST(includesubdir)
2242 includesubdir=
2243 if test "$with_overwrite" = no && \
2244  ( test "x$includedir" = 'x${prefix}/include' || \
2245    test "x$includedir" = "x${prefix}/include" )
2246 then
2247         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2248 fi
2249 AC_MSG_RESULT(${includedir}${includesubdir})
2250
2251 ### Resolve a conflict between normal and wide-curses by forcing applications
2252 ### that will need libutf8 to add it to their configure script.
2253 if test "$with_overwrite" != no ; then
2254 if test "$NCURSES_LIBUTF8" = 1 ; then
2255         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2256         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2257 fi
2258 fi
2259 WITH_OVERWRITE=$with_overwrite
2260
2261 ### At least on MinGW a shared library build without libtool
2262 ### requires adding the additional libs to the link list.
2263 case $cf_cv_system_name in
2264 (*mingw32*|*mingw64*)
2265         if test "$DFT_LWR_MODEL" != "libtool"; then
2266            SHLIB_LIST="$SHLIB_LIST ${LIBS}"
2267         fi
2268         ;;
2269 *)      ;;
2270 esac
2271
2272 AC_SUBST(WITH_OVERWRITE)
2273 AC_SUBST(TICS_LIST)
2274 AC_SUBST(TINFO_LIST)
2275 AC_SUBST(SHLIB_LIST)
2276
2277 # used to separate tack out of the tree
2278 NCURSES_TREE=
2279 AC_SUBST(NCURSES_TREE)
2280
2281 ### predefined stuff for the test programs
2282 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2283
2284 # pkgsrc uses these
2285 CF_WITH_LIB_BASENAME(FORM_NAME,form)
2286 CF_WITH_LIB_BASENAME(MENU_NAME,menu)
2287 CF_WITH_LIB_BASENAME(PANEL_NAME,panel)
2288 CF_WITH_LIB_BASENAME(CXX_NAME,cxx,ncurses++)
2289
2290 ### Construct the list of subdirectories for which we'll customize makefiles
2291 ### with the appropriate compile-rules.
2292
2293 CF_SRC_MODULES($modules_to_build)
2294
2295 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2296    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/src/library.gpr:Ada95/src/library.gpr.in"
2297    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2298    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2299 fi
2300
2301 CF_DIRS_TO_MAKE
2302
2303 # symbols that differ when compiling Ada95 by itself.
2304 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2305 AC_SUBST(NCURSES_SHLIB2)
2306
2307 # values to use as strings
2308 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2309
2310 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2311
2312 ### Define substitutions for header files to avoid name-pollution
2313 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2314 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2315 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2316 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2317
2318 ################################################################################
2319 test "x$use_database" = xyes && \
2320 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2321
2322 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2323 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2324
2325 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2326 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2327 fi
2328 AC_SUBST(cross_compiling)
2329
2330 if test "x$cf_with_tests" != xno ; then
2331         MAKE_TESTS=
2332 else
2333         MAKE_TESTS="#"
2334 fi
2335 AC_SUBST(MAKE_TESTS)
2336
2337 ADAHTML_DIR=../../doc/html/ada
2338 AC_SUBST(ADAHTML_DIR)
2339
2340 # workaround for OS/2 (20151017)
2341 case $cf_cv_system_name in
2342 (os2*)
2343         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2344         ;;
2345 (*)
2346         LIBTOOL_OPTS_CXX=
2347         ;;
2348 esac
2349 AC_SUBST(LIBTOOL_OPTS_CXX)
2350
2351 # workaround for g++ versus Solaris (20131116)
2352 case $cf_cv_system_name in
2353 (solaris2*)
2354         case "x$CPPFLAGS" in
2355         (*-D_XOPEN_SOURCE_EXTENDED*)
2356                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2357                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2358                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2359                 ;;
2360         esac
2361         ;;
2362 esac
2363
2364 # Help to automatically enable the extended curses features when using either
2365 # the *-config or the ".pc" files by adding defines.
2366 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2367 PKG_CFLAGS=
2368 for cf_loop1 in $CPPFLAGS_after_XOPEN
2369 do
2370         cf_found=no
2371         for cf_loop2 in $CPPFLAGS_before_XOPEN
2372         do
2373                 if test "x$cf_loop1" = "x$cf_loop2"
2374                 then
2375                         cf_found=yes
2376                         break
2377                 fi
2378         done
2379         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2380 done
2381 AC_MSG_RESULT($PKG_CFLAGS)
2382 AC_SUBST(PKG_CFLAGS)
2383
2384 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2385 case "x$NCURSES_OSPEED" in
2386 (*short*)
2387         cf_compatible=1
2388         ;;
2389 (*)
2390         cf_compatible=0
2391         ;;
2392 esac
2393 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2394
2395 case "x$cf_cv_typeof_chtype" in
2396 (xshort|xint|xlong)
2397         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2398         ;;
2399 esac
2400
2401 case "x$cf_cv_typeof_mmask_t" in
2402 (xshort|xint|xlong)
2403         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2404         ;;
2405 esac
2406
2407 # substitute into misc/Makefile to suppress
2408 # (un)install.data from the
2409 # (un)install rules.
2410 if test "x$cf_with_db_install" = "xno"; then
2411         MISC_INSTALL_DATA=
2412         MISC_UNINSTALL_DATA=
2413 else
2414         MISC_INSTALL_DATA=install.data
2415         MISC_UNINSTALL_DATA=uninstall.data
2416 fi
2417 AC_SUBST(MISC_INSTALL_DATA)
2418 AC_SUBST(MISC_UNINSTALL_DATA)
2419
2420 if test "x$cf_with_db_install" = "xno" || test "x$TERMINFO_SRC" = "xno"; then
2421         MAKE_DATABASE="#"
2422 else
2423         MAKE_DATABASE="$MAKE_TERMINFO"
2424 fi
2425 AC_SUBST(MAKE_DATABASE)
2426
2427 dnl Override the package used for exported symbols
2428 if test -n "$PACKAGE"
2429 then
2430         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2431         export PACKAGE
2432         echo "package: $PACKAGE"
2433 fi
2434
2435 UNALTERED_SYMS=
2436 cf_filter_syms=no
2437
2438 if test -n "$RESULTING_SYMS"
2439 then
2440         cf_filter_syms=$cf_dft_filter_syms
2441         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_version)
2442 fi
2443
2444 if test "x$WILDCARD_SYMS" = xno
2445 then
2446         cf_filter_syms=yes
2447 fi
2448
2449 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2450
2451 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2452 if test $cf_filter_syms = yes
2453 then
2454         RESULTING_SYMS=resulting.map
2455 fi
2456 AC_SUBST(UNALTERED_SYMS)
2457
2458 if test "x$cross_compiling" = xyes ; then
2459         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2460         CHECK_BUILD="#"
2461 else
2462         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2463         CHECK_BUILD=
2464 fi
2465 AC_SUBST(ADAGEN_LDFLAGS)
2466 AC_SUBST(CHECK_BUILD)
2467 AC_SUBST(PRIVATE_LIBS)
2468
2469 # This is used for the *-config script and *.pc data files.
2470 CF_LD_SEARCHPATH
2471
2472 AC_DEFINE(HAVE_CURSES_DATA_BOOLNAMES,1,[definition needed for in-tree build of tack])
2473
2474 AC_OUTPUT( \
2475         include/MKterm.h.awk \
2476         include/curses.head:include/curses.h.in \
2477         include/ncurses_dll.h \
2478         include/termcap.h \
2479         include/unctrl.h \
2480         $SUB_MAKEFILES \
2481         Makefile,[
2482 if test "x$cf_with_tests" != xno ; then
2483         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2484 fi
2485 CF_LIB_RULES($SRC_SUBDIRS)
2486
2487 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2488 if test -z "$USE_OLD_MAKERULES" ; then
2489         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
2490 fi
2491 fi
2492 ],[
2493 ### Special initialization commands, used to pass information from the
2494 ### configuration-run into config.status
2495
2496 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2497 AWK="$AWK"
2498 CXX_NAME="$CXX_NAME"
2499 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2500 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2501 ECHO_LD="$ECHO_LD"
2502 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2503 FORM_NAME="$FORM_NAME"
2504 LDCONFIG="$LDCONFIG"
2505 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2506 LIB_NAME="$LIB_NAME"
2507 LIB_PREFIX="$LIB_PREFIX"
2508 LIB_SUBSETS="$LIB_SUBSETS"
2509 LIB_SUFFIX="$LIB_SUFFIX"
2510 LIB_TRACING="$LIB_TRACING"
2511 LN_S="$LN_S"
2512 MAKE_TERMINFO="$MAKE_TERMINFO"
2513 MENU_NAME="$MENU_NAME"
2514 NCURSES_MAJOR="$NCURSES_MAJOR"
2515 NCURSES_MINOR="$NCURSES_MINOR"
2516 NCURSES_OSPEED="$NCURSES_OSPEED"
2517 NCURSES_PATCH="$NCURSES_PATCH"
2518 PANEL_NAME="$PANEL_NAME"
2519 SRC_SUBDIRS="$SRC_SUBDIRS"
2520 TERMINFO="$TERMINFO"
2521 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2522 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2523 TICS_NAME="$TICS_NAME"
2524 TICS_SUFFIX="$TICS_SUFFIX"
2525 TIC_PATH="$TIC_PATH"
2526 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2527 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2528 TINFO_NAME="$TINFO_NAME"
2529 TINFO_SUFFIX="$TINFO_SUFFIX"
2530 UNALTERED_SYMS="$UNALTERED_SYMS"
2531 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2532 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2533 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2534 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2535 WILDCARD_SYMS="$WILDCARD_SYMS"
2536 WITH_CURSES_H="$with_curses_h"
2537 WITH_ECHO="${enable_echo:=yes}"
2538 WITH_OVERWRITE="$with_overwrite"
2539 cf_LIST_MODELS="$cf_list_models"
2540 cf_cv_abi_version="$cf_cv_abi_version"
2541 cf_cv_do_relink="$cf_cv_do_relink"
2542 cf_cv_do_reranlib="$cf_cv_do_reranlib"
2543 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2544 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2545 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2546 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2547 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2548 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2549 cf_cv_rel_version="$cf_cv_rel_version"
2550 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2551 cf_cv_shared_soname='$cf_cv_shared_soname'
2552 cf_cv_shlib_version="$cf_cv_shlib_version"
2553 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2554 cf_cv_system_name="$cf_cv_system_name"
2555 cf_cv_term_driver="$with_term_driver"
2556 cf_with_ada="$cf_with_ada"
2557 cf_with_cxx_binding="$cf_with_cxx_binding"
2558 cf_with_db_install="$cf_with_db_install"
2559 cf_with_manpages="$cf_with_manpages"
2560 cf_with_tests="$cf_with_tests"
2561 host="$host"
2562 target="$target"
2563 with_shared_cxx="$with_shared_cxx"
2564
2565 ],cat)dnl
2566 ${MAKE:-make} preinstall