configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2006,2007 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.431 2008/03/29 18:38:08 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.13.20020210)
  38 AC_REVISION($Revision: 1.431 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44
  45 CF_WITH_REL_VERSION(NCURSES)
  46 CF_WITH_ABI_VERSION
  47
  48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
  49 AC_ARG_WITH(system-type,
  50 [  --with-system-type=XXX  test: override derived host system-type],
  51 [AC_MSG_WARN(overriding system type to $withval)
  52  cf_cv_system_name=$withval])
  53
  54 ###     Save the given $CFLAGS to allow user-override.
  55 cf_user_CFLAGS="$CFLAGS"
  56
  57 ###     Default install-location
  58 CF_CFG_DEFAULTS
  59
  60 ###     Checks for programs.
  61 AC_PROG_CC
  62 CF_GCC_VERSION
  63
  64 AC_PROG_CPP
  65 AC_PROG_GCC_TRADITIONAL
  66 CF_PROG_CC_C_O(CC)
  67 AC_ISC_POSIX
  68 CF_ANSI_CC_REQD
  69 CF_PROG_EXT
  70 CF_PROG_LDCONFIG
  71
  72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  73 dnl                             configure script by not letting us test if C++
  74 dnl                             is present, making this option necessary.
  75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  76 AC_ARG_WITH(cxx,
  77         [  --without-cxx           do not adjust ncurses bool to match C++],
  78         [cf_with_cxx=$withval],
  79         [cf_with_cxx=yes])
  80 AC_MSG_RESULT($cf_with_cxx)
  81 if test "X$cf_with_cxx" = Xno ; then
  82         CXX=""
  83         GXX=""
  84 else
  85         # with autoconf 2.13, we can change the error to a warning:
  86         pushdef([AC_MSG_ERROR],
  87                 [AC_MSG_RESULT(no)
  88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  90         AC_PROG_CXX
  91         popdef([AC_MSG_ERROR])dnl
  92         # autoconf 2.5x removed the error - by hardcoding it to g++.
  93         if test "$CXX" = "g++" ; then
  94                 AC_PATH_PROG(CXX,g++)
  95         fi
  96         if test "$CXX" = "g++" ; then
  97                 AC_MSG_WARN(ignoring hardcoded g++)
  98                 cf_with_cxx=no; CXX=""; GXX="";
  99         fi
 100 fi
 101
 102 CF_GXX_VERSION
 103 case $GXX_VERSION in
 104 1*|2.[[0-6]]*)
 105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 106         # cf_cxx_library=no
 107         AC_MSG_WARN(templates do not work)
 108         ;;
 109 esac
 110
 111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 112 AC_ARG_WITH(cxx-binding,
 113         [  --without-cxx-binding   do not build C++ binding and demo],
 114         [cf_with_cxx_binding=$withval],
 115         [cf_with_cxx_binding=$cf_with_cxx])
 116 AC_MSG_RESULT($cf_with_cxx_binding)
 117
 118 AC_MSG_CHECKING(if you want to build with Ada95)
 119 AC_ARG_WITH(ada,
 120         [  --without-ada           suppress check for Ada95, don't build demo],
 121         [cf_with_ada=$withval],
 122         [cf_with_ada=yes])
 123 AC_MSG_RESULT($cf_with_ada)
 124
 125 AC_MSG_CHECKING(if you want to build programs such as tic)
 126 AC_ARG_WITH(progs,
 127         [  --without-progs         suppress build with programs (e.g., tic)],
 128         [cf_with_progs=$withval],
 129         [cf_with_progs=yes])
 130 AC_MSG_RESULT($cf_with_progs)
 131
 132 AC_MSG_CHECKING(if you wish to install curses.h)
 133 AC_ARG_WITH(curses-h,
 134         [  --without-curses-h      install curses.h as ncurses.h only],
 135         [with_curses_h=$withval],
 136         [with_curses_h=yes])
 137 AC_MSG_RESULT($with_curses_h)
 138
 139 modules_to_build="ncurses"
 140 if test "X$cf_with_progs" != Xno ; then
 141 modules_to_build="$modules_to_build progs tack"
 142 fi
 143 modules_to_build="$modules_to_build panel menu form"
 144
 145 AC_ARG_PROGRAM
 146
 147 CF_PROG_AWK
 148 CF_PROG_EGREP
 149 CF_PROG_INSTALL
 150 CF_PROG_LINT
 151 AC_PROG_LN_S
 152
 153 AC_SYS_LONG_FILE_NAMES
 154
 155 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 156 AC_ARG_ENABLE(mixed-case,
 157         [  --enable-mixed-case     tic should assume mixed-case filenames],
 158         [enable_mixedcase=$enableval],
 159         [enable_mixedcase=auto])
 160 AC_MSG_RESULT($enable_mixedcase)
 161 if test "$enable_mixedcase" = "auto" ; then
 162     CF_MIXEDCASE_FILENAMES
 163 else
 164     cf_cv_mixedcase=$enable_mixedcase
 165     if test "$enable_mixedcase" = "yes" ; then
 166         AC_DEFINE(MIXEDCASE_FILENAMES)
 167     fi
 168 fi
 169
 170 # do this after mixed-case option (tags/TAGS is not as important as tic).
 171 AC_PROG_MAKE_SET
 172 CF_MAKE_TAGS
 173 CF_MAKEFLAGS
 174
 175 dnl These are standard among *NIX systems, but not when cross-compiling
 176 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 177 AC_CHECK_TOOL(LD, ld, ld)
 178 AC_CHECK_TOOL(AR, ar, ar)
 179 CF_SUBST(archiver options,AR_OPTS,rv)
 180
 181 dnl Special option for use by system-builders: the install-prefix is used to
 182 dnl adjust the location into which the actual install is done, so that an
 183 dnl archive can be built without modifying the host system's configuration.
 184 AC_MSG_CHECKING(if you have specified an install-prefix)
 185 AC_ARG_WITH(install-prefix,
 186         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 187         [case "$withval" in #(vi
 188         yes|no) #(vi
 189                 ;;
 190         *)      DESTDIR="$withval"
 191                 ;;
 192         esac])
 193 AC_MSG_RESULT($DESTDIR)
 194 AC_SUBST(DESTDIR)
 195
 196 ###############################################################################
 197 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 198 # If we're cross-compiling, allow the user to override the tools and their
 199 # options.  The configure script is oriented toward identifying the host
 200 # compiler, etc., but we need a build compiler to generate parts of the source.
 201 CF_BUILD_CC
 202
 203 ###############################################################################
 204 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 205
 206 ### Options to allow the user to specify the set of libraries which are used.
 207 ### Use "--without-normal --with-shared" to allow the default model to be
 208 ### shared, for example.
 209 cf_list_models=""
 210 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 211
 212 CF_WITH_LIBTOOL
 213 if test "$with_libtool" != "no" ; then
 214
 215 cf_list_models="$cf_list_models libtool"
 216
 217 else
 218
 219 AC_MSG_CHECKING(if you want to build shared libraries)
 220 AC_ARG_WITH(shared,
 221         [  --with-shared           generate shared-libraries],
 222         [with_shared=$withval],
 223         [with_shared=no])
 224 AC_MSG_RESULT($with_shared)
 225 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
 226
 227 AC_MSG_CHECKING(if you want to build static libraries)
 228 AC_ARG_WITH(normal,
 229         [  --with-normal           generate normal-libraries (default)],
 230         [with_normal=$withval],
 231         [with_normal=yes])
 232 AC_MSG_RESULT($with_normal)
 233 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
 234
 235 AC_MSG_CHECKING(if you want to build debug libraries)
 236 AC_ARG_WITH(debug,
 237         [  --with-debug            generate debug-libraries (default)],
 238         [with_debug=$withval],
 239         [with_debug=yes])
 240 AC_MSG_RESULT($with_debug)
 241 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
 242
 243 AC_MSG_CHECKING(if you want to build profiling libraries)
 244 AC_ARG_WITH(profile,
 245         [  --with-profile          generate profile-libraries],
 246         [with_profile=$withval],
 247         [with_profile=no])
 248 AC_MSG_RESULT($with_profile)
 249 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
 250
 251 fi
 252
 253 ###############################################################################
 254
 255 AC_MSG_CHECKING(for specified models)
 256 test -z "$cf_list_models" && cf_list_models=normal
 257 dnl If we use libtool to generate libraries, then it must be the only
 258 dnl specified model.
 259 test "$with_libtool" != "no" && cf_list_models=libtool
 260 AC_MSG_RESULT($cf_list_models)
 261
 262 ### Use the first model as the default, and save its suffix for use in building
 263 ### up test-applications.
 264 AC_MSG_CHECKING(for default model)
 265 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 266 AC_MSG_RESULT($DFT_LWR_MODEL)
 267
 268 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 269
 270 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 271 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 272
 273 TICS_NAME=tic
 274 AC_SUBST(TICS_NAME)
 275
 276 TINFO_NAME=tinfo
 277 AC_SUBST(TINFO_NAME)
 278
 279 LIB_NAME=ncurses
 280 AC_SUBST(LIB_NAME)
 281
 282 LIB_DIR=../lib
 283 LIB_2ND=../../lib
 284
 285 CF_LIB_PREFIX(cf_prefix)
 286 LIB_PREFIX=$cf_prefix
 287 AC_SUBST(LIB_PREFIX)
 288
 289 LIB_SUFFIX=
 290 AC_SUBST(LIB_SUFFIX)
 291
 292 ###############################################################################
 293
 294 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 295 AC_ARG_WITH(termlib,
 296         [  --with-termlib          generate separate terminfo library],
 297         [with_termlib=$withval],
 298         [with_termlib=no])
 299 AC_MSG_RESULT($with_termlib)
 300
 301 AC_MSG_CHECKING(if you want to build a separate tic library)
 302 AC_ARG_WITH(ticlib,
 303         [  --with-ticlib           generate separate tic library],
 304         [with_ticlib=$withval],
 305         [with_ticlib=no])
 306 AC_MSG_RESULT($with_ticlib)
 307
 308 ### Checks for special libraries, must be done up-front.
 309 SHLIB_LIST=""
 310 CF_WITH_GPM
 311 if test "$with_gpm" != no ; then
 312         AC_MSG_CHECKING(if you want to load GPM dynamically)
 313         AC_ARG_WITH(dlsym,
 314                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 315                 [with_dlsym=$withval],
 316                 [with_dlsym=yes])
 317         AC_MSG_RESULT($with_dlsym)
 318         if test "$with_dlsym" = yes ; then
 319                 CF_FUNC_DLSYM
 320                 if test "$with_gpm" != yes ; then
 321                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 322                         cf_cv_gpm_soname="$with_gpm"
 323                 else
 324                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 325                 fi
 326                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
 327                 SHLIB_LIST="-ldl $SHLIB_LIST"
 328         else
 329                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 330         fi
 331         AC_DEFINE(HAVE_LIBGPM)
 332         CF_CHECK_GPM_WGETCH
 333 fi
 334
 335 CF_WITH_SYSMOUSE
 336
 337 dnl Not all ports of gcc support the -g option
 338
 339 if test X"$CC_G_OPT" = X"" ; then
 340         CC_G_OPT='-g'
 341         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
 342 fi
 343 AC_SUBST(CC_G_OPT)
 344
 345 if test X"$CXX_G_OPT" = X"" ; then
 346         CXX_G_OPT='-g'
 347         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
 348 fi
 349 AC_SUBST(CXX_G_OPT)
 350
 351 AC_MSG_CHECKING(for default loader flags)
 352 case $DFT_LWR_MODEL in
 353 libtool) LD_MODEL=''   ;;
 354 normal)  LD_MODEL=''   ;;
 355 debug)   LD_MODEL=$CC_G_OPT ;;
 356 profile) LD_MODEL='-pg';;
 357 shared)  LD_MODEL=''   ;;
 358 esac
 359 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 360 AC_MSG_RESULT($LD_MODEL)
 361
 362 case $DFT_LWR_MODEL in
 363 shared)
 364 AC_MSG_CHECKING(if rpath option should be used)
 365 AC_ARG_ENABLE(rpath,
 366 [  --enable-rpath          use rpath option when generating shared libraries],
 367 [cf_cv_ld_rpath=$enableval],
 368 [cf_cv_ld_rpath=no])
 369 AC_MSG_RESULT($cf_cv_ld_rpath)
 370 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 371 AC_ARG_ENABLE(relink,
 372 [  --disable-relink        relink shared libraries during install],
 373 [cf_cv_do_relink=$enableval],
 374 [cf_cv_do_relink=yes])
 375 AC_MSG_RESULT($cf_cv_do_relink)
 376         ;;
 377 esac
 378
 379 CF_SHARED_OPTS
 380 if test "$CC_SHARED_OPTS" = "unknown"; then
 381         for model in $cf_list_models; do
 382                 if test "$model" = "shared"; then
 383                         AC_ERROR(Shared libraries are not supported in this version)
 384                 fi
 385         done
 386 fi
 387
 388 ###############################################################################
 389 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 390
 391 ###     use option --disable-overwrite to leave out the link to -lcurses
 392 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 393 AC_ARG_ENABLE(overwrite,
 394         [  --disable-overwrite     leave out the link to -lcurses],
 395         [with_overwrite=$enableval],
 396         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 397 AC_MSG_RESULT($with_overwrite)
 398
 399 AC_MSG_CHECKING(if external terminfo-database is used)
 400 AC_ARG_ENABLE(database,
 401         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 402         [use_database=$enableval],
 403         [use_database=yes])
 404 AC_MSG_RESULT($use_database)
 405
 406 case $host_os in #(vi
 407 os2*) #(vi
 408         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 409         ;;
 410 *) #(vi
 411         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 412         ;;
 413 esac
 414 AC_SUBST(TERMINFO_SRC)
 415
 416 CF_PATHSEP
 417 if test "$use_database" != no ; then
 418         AC_DEFINE(USE_DATABASE)
 419
 420         AC_MSG_CHECKING(which terminfo source-file will be installed)
 421         AC_ARG_ENABLE(database,
 422                 [  --with-database=XXX     specify terminfo source to install],
 423                 [TERMINFO_SRC=$withval])
 424         AC_MSG_RESULT($TERMINFO_SRC)
 425
 426         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 427         AC_ARG_WITH(hashed-db,
 428                 [  --with-hashed-db        specify hashed-database library],,
 429                 [with_hashed_db=no])
 430         AC_MSG_RESULT($with_hashed_db)
 431 fi
 432
 433 AC_MSG_CHECKING(for list of fallback descriptions)
 434 AC_ARG_WITH(fallbacks,
 435         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 436         [with_fallback=$withval],
 437         [with_fallback=])
 438 AC_MSG_RESULT($with_fallback)
 439 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 440 AC_SUBST(FALLBACK_LIST)
 441
 442 AC_MSG_CHECKING(if you want modern xterm or antique)
 443 AC_ARG_WITH(xterm-new,
 444         [  --without-xterm-new     specify if xterm terminfo should be old version],
 445         [with_xterm_new=$withval],
 446         [with_xterm_new=yes])
 447 case $with_xterm_new in
 448 no)     with_xterm_new=xterm-old;;
 449 *)      with_xterm_new=xterm-new;;
 450 esac
 451 AC_MSG_RESULT($with_xterm_new)
 452 WHICH_XTERM=$with_xterm_new
 453 AC_SUBST(WHICH_XTERM)
 454
 455 MAKE_TERMINFO=
 456 if test "$use_database" = no ; then
 457         TERMINFO="${datadir}/terminfo"
 458         MAKE_TERMINFO="#"
 459 else
 460
 461 AC_MSG_CHECKING(for list of terminfo directories)
 462 CF_WITH_PATHLIST(terminfo-dirs,
 463         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 464         TERMINFO_DIRS,
 465         DATADIR/terminfo,
 466         ${datadir}/terminfo)
 467 AC_MSG_RESULT($TERMINFO_DIRS)
 468 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
 469
 470 AC_MSG_CHECKING(for default terminfo directory)
 471 CF_WITH_PATH(default-terminfo-dir,
 472         [  --with-default-terminfo-dir=DIR default terminfo directory],
 473         TERMINFO,
 474         DATADIR/terminfo,
 475         ${datadir}/terminfo)
 476 AC_MSG_RESULT($TERMINFO)
 477 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
 478
 479 fi
 480
 481 AC_SUBST(TERMINFO)
 482 AC_SUBST(MAKE_TERMINFO)
 483
 484 ###     use option --disable-big-core to make tic run on small machines
 485 ###     We need 4Mb, check if we can allocate 50% more than that.
 486 AC_MSG_CHECKING(if big-core option selected)
 487 AC_ARG_ENABLE(big-core,
 488         [  --disable-big-core      assume machine has little memory],
 489         [with_big_core=$enableval],
 490         [AC_TRY_RUN([
 491 #include <stdlib.h>
 492 #include <string.h>
 493 int main() {
 494         unsigned long n = 6000000L;
 495         char *s = malloc(n);
 496         if (s != 0)
 497                 s[0] = s[n-1] = 0;
 498         ${cf_cv_main_return:-return}(s == 0);
 499 }],
 500         [with_big_core=yes],
 501         [with_big_core=no],
 502         [with_big_core=no])])
 503 AC_MSG_RESULT($with_big_core)
 504 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
 505
 506 ### ISO C only guarantees 512-char strings, we have tables which load faster
 507 ### when constructed using "big" strings.
 508 AC_MSG_CHECKING(if big-strings option selected)
 509 AC_ARG_ENABLE(big-strings,
 510         [  --disable-big-strings   assume compiler has only standard-size strings],
 511         [with_big_strings=no],
 512         [with_big_strings=yes])
 513 AC_MSG_RESULT($with_big_strings)
 514
 515 USE_BIG_STRINGS=0
 516 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
 517 AC_SUBST(USE_BIG_STRINGS)
 518
 519 ###     use option --enable-termcap to compile in the termcap fallback support
 520 AC_MSG_CHECKING(if you want termcap-fallback support)
 521 AC_ARG_ENABLE(termcap,
 522         [  --enable-termcap        compile in termcap fallback support],
 523         [with_termcap=$enableval],
 524         [with_termcap=no])
 525 AC_MSG_RESULT($with_termcap)
 526
 527 if test "$with_termcap" != "yes" ; then
 528         if test "$use_database" = no ; then
 529                 if test -z "$with_fallback" ; then
 530                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 531                 fi
 532         fi
 533         AC_DEFINE(PURE_TERMINFO)
 534 else
 535
 536 if test "$with_ticlib" != no ; then
 537         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 538 fi
 539
 540 AC_DEFINE(USE_TERMCAP)
 541 AC_MSG_CHECKING(for list of termcap files)
 542 CF_WITH_PATHLIST(termpath,
 543         [  --with-termpath=XXX     specify list of termcap files],
 544         TERMPATH,
 545         /etc/termcap:/usr/share/misc/termcap)
 546 AC_MSG_RESULT($TERMPATH)
 547 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
 548
 549 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 550 AC_MSG_CHECKING(if fast termcap-loader is needed)
 551 AC_ARG_ENABLE(getcap,
 552         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 553         [with_getcap=$enableval],
 554         [with_getcap=no])
 555 AC_MSG_RESULT($with_getcap)
 556 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
 557
 558 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 559 AC_ARG_ENABLE(getcap-cache,
 560         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 561         [with_getcap_cache=$enableval],
 562         [with_getcap_cache=no])
 563 AC_MSG_RESULT($with_getcap_cache)
 564 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
 565
 566 fi
 567
 568 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 569 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 570 AC_ARG_ENABLE(home-terminfo,
 571         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 572         [with_home_terminfo=$enableval],
 573         [with_home_terminfo=yes])
 574 AC_MSG_RESULT($with_home_terminfo)
 575 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
 576
 577 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 578 AC_ARG_ENABLE(root-environ,
 579         [  --disable-root-environ  restrict environment when running as root],
 580         [with_root_environ=$enableval],
 581         [with_root_environ=yes])
 582 AC_MSG_RESULT($with_root_environ)
 583 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
 584
 585 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 586 ###   to reduce storage requirements for the terminfo database.
 587 CF_LINK_FUNCS
 588
 589 with_links=no
 590 with_symlinks=no
 591
 592 # soft links (symbolic links) are useful for some systems where hard links do
 593 # not work, or to make it simpler to copy terminfo trees around.
 594 if test "$ac_cv_func_symlink" = yes ; then
 595     AC_MSG_CHECKING(if tic should use symbolic links)
 596     AC_ARG_ENABLE(symlinks,
 597         [  --enable-symlinks       make tic use symbolic links not hard links],
 598         [with_symlinks=$enableval],
 599         [with_symlinks=no])
 600     AC_MSG_RESULT($with_symlinks)
 601 fi
 602
 603 # If we have hard links and did not choose to use soft links instead, there is
 604 # no reason to make this choice optional - use the hard links.
 605 if test "$with_symlinks" = no ; then
 606     AC_MSG_CHECKING(if tic should use hard links)
 607     if test "$ac_cv_func_link" = yes ; then
 608         with_links=yes
 609     else
 610         with_links=no
 611     fi
 612     AC_MSG_RESULT($with_links)
 613 fi
 614
 615 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
 616 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
 617
 618 ###   use option --enable-broken-linker to force on use of broken-linker support
 619 AC_MSG_CHECKING(if you want broken-linker support code)
 620 AC_ARG_ENABLE(broken_linker,
 621         [  --enable-broken_linker  compile with broken-linker support code],
 622         [with_broken_linker=$enableval],
 623         [with_broken_linker=${BROKEN_LINKER-no}])
 624 AC_MSG_RESULT($with_broken_linker)
 625
 626 BROKEN_LINKER=0
 627 if test "$with_broken_linker" = yes ; then
 628         AC_DEFINE(BROKEN_LINKER)
 629         BROKEN_LINKER=1
 630 elif test "$DFT_LWR_MODEL" = shared ; then
 631         case $cf_cv_system_name in #(vi
 632         cygwin*)
 633                 AC_DEFINE(BROKEN_LINKER)
 634                 BROKEN_LINKER=1
 635                 CF_VERBOSE(cygwin linker is broken anyway)
 636                 ;;
 637         esac
 638 fi
 639 AC_SUBST(BROKEN_LINKER)
 640
 641 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 642 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 643 AC_ARG_ENABLE(bsdpad,
 644         [  --enable-bsdpad         recognize BSD-style prefix padding],
 645         [with_bsdpad=$enableval],
 646         [with_bsdpad=no])
 647 AC_MSG_RESULT($with_bsdpad)
 648 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
 649
 650 ###   use option --enable-widec to turn on use of wide-character support
 651 NCURSES_CH_T=chtype
 652 NCURSES_LIBUTF8=0
 653
 654 NEED_WCHAR_H=0
 655 NCURSES_MBSTATE_T=0
 656 NCURSES_WCHAR_T=0
 657 NCURSES_WINT_T=0
 658
 659 # Check to define _XOPEN_SOURCE "automatically"
 660 CF_XOPEN_SOURCE
 661
 662 # Work around breakage on OS X
 663 CF_SIGWINCH
 664
 665 # Checks for CODESET support.
 666 AM_LANGINFO_CODESET
 667
 668 # use these variables to work around a defect in gcc's fixincludes.
 669 NCURSES_OK_WCHAR_T=
 670 NCURSES_OK_WINT_T=
 671
 672 AC_MSG_CHECKING(if you want wide-character code)
 673 AC_ARG_ENABLE(widec,
 674         [  --enable-widec          compile with wide-char/UTF-8 code],
 675         [with_widec=$enableval],
 676         [with_widec=no])
 677 AC_MSG_RESULT($with_widec)
 678 if test "$with_widec" = yes ; then
 679         LIB_SUFFIX="w${LIB_SUFFIX}"
 680         AC_DEFINE(USE_WIDEC_SUPPORT)
 681         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 682         # with_overwrite=no
 683         NCURSES_CH_T=cchar_t
 684         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc)
 685         if test "$ac_cv_func_putwc" != yes ; then
 686                 CF_LIBUTF8
 687                 if test "$cf_cv_libutf8" = yes ; then
 688                         NCURSES_LIBUTF8=1
 689                 fi
 690         fi
 691         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 692         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 693         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 694
 695         if test "$NCURSES_MBSTATE_T" != 0; then
 696                 AC_DEFINE(NEED_MBSTATE_T_DEF)
 697         fi
 698 fi
 699 AC_SUBST(NCURSES_CH_T)
 700 AC_SUBST(NCURSES_LIBUTF8)
 701
 702 AC_SUBST(NEED_WCHAR_H)
 703 AC_SUBST(NCURSES_MBSTATE_T)
 704 AC_SUBST(NCURSES_WCHAR_T)
 705 AC_SUBST(NCURSES_WINT_T)
 706
 707 AC_SUBST(NCURSES_OK_WCHAR_T)
 708 AC_SUBST(NCURSES_OK_WINT_T)
 709
 710 ###   use option --disable-lp64 to allow long chtype
 711 case $cf_cv_abi_version in
 712 [[345]]*)
 713         default_with_lp64=no
 714         ;;
 715 *)
 716         default_with_lp64=yes
 717         ;;
 718 esac
 719
 720 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 721 AC_ARG_ENABLE(lp64,
 722         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 723         [with_lp64=$enableval],
 724         [with_lp64=$default_with_lp64])
 725 AC_MSG_RESULT($with_lp64)
 726
 727 if test "$with_lp64" = yes ; then
 728         cf_cv_enable_lp64=1
 729 else
 730         cf_cv_enable_lp64=0
 731 fi
 732 AC_SUBST(cf_cv_enable_lp64)
 733
 734 CF_LARGEFILE
 735
 736 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 737 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 738 AC_ARG_ENABLE(tparm-varargs,
 739         [  --disable-tparm-varargs compile tparm() without varargs interface],
 740         [with_tparm_varargs=$enableval],
 741         [with_tparm_varargs=yes])
 742 AC_MSG_RESULT($with_tparm_varargs)
 743 NCURSES_TPARM_VARARGS=0
 744 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
 745 AC_SUBST(NCURSES_TPARM_VARARGS)
 746
 747 ###   use option --with-bool to override bool's type
 748 AC_MSG_CHECKING(for type of bool)
 749 AC_ARG_WITH(bool,
 750         [  --with-bool=TYPE        override fallback type of bool variable],
 751         [NCURSES_BOOL="$withval"],
 752         [NCURSES_BOOL=auto])
 753 AC_MSG_RESULT($NCURSES_BOOL)
 754 AC_SUBST(NCURSES_BOOL)
 755
 756 AC_MSG_CHECKING(for alternate terminal capabilities file)
 757 AC_ARG_WITH(caps,
 758         [  --with-caps=alt         compile with alternate Caps file],
 759         [TERMINFO_CAPS=Caps.$withval],
 760         [TERMINFO_CAPS=Caps])
 761 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 762 AC_MSG_RESULT($TERMINFO_CAPS)
 763 AC_SUBST(TERMINFO_CAPS)
 764
 765 ###   use option --with-chtype to override chtype's type
 766 AC_MSG_CHECKING(for type of chtype)
 767 AC_ARG_WITH(chtype,
 768         [  --with-chtype=TYPE      override type of chtype],
 769         [NCURSES_CHTYPE="$withval"],
 770         [NCURSES_CHTYPE=auto])
 771 AC_MSG_RESULT($NCURSES_CHTYPE)
 772
 773 ###   use option --with-ospeed to override ospeed's type
 774 AC_MSG_CHECKING(for type of ospeed)
 775 AC_ARG_WITH(ospeed,
 776         [  --with-ospeed=TYPE      override type of ospeed variable],
 777         [NCURSES_OSPEED="$withval"],
 778         [NCURSES_OSPEED=short])
 779 AC_MSG_RESULT($NCURSES_OSPEED)
 780 AC_SUBST(NCURSES_OSPEED)
 781
 782 ###   use option --with-mmask-t to override mmask_t's type
 783 AC_MSG_CHECKING(for type of mmask_t)
 784 AC_ARG_WITH(mmask-t,
 785         [  --with-mmask-t=TYPE     override type of mmask_t],
 786         [NCURSES_MMASK_T="$withval"],
 787         [NCURSES_MMASK_T=auto])
 788 AC_MSG_RESULT($NCURSES_MMASK_T)
 789
 790 ### Enable compiling-in rcs id's
 791 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
 792 AC_ARG_WITH(rcs-ids,
 793         [  --with-rcs-ids          compile-in RCS identifiers],
 794         [with_rcs_ids=$withval],
 795         [with_rcs_ids=no])
 796 AC_MSG_RESULT($with_rcs_ids)
 797 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
 798
 799 ###############################################################################
 800 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tic toe tput ])
 801
 802 ###############################################################################
 803 CF_HELP_MESSAGE(Extensions:)
 804
 805 ### Note that some functions (such as const) are normally disabled anyway.
 806 AC_MSG_CHECKING(if you want to build with function extensions)
 807 AC_ARG_ENABLE(ext-funcs,
 808         [  --disable-ext-funcs     disable function-extensions],
 809         [with_ext_funcs=$enableval],
 810         [with_ext_funcs=yes])
 811 AC_MSG_RESULT($with_ext_funcs)
 812 if test "$with_ext_funcs" = yes ; then
 813         NCURSES_EXT_FUNCS=1
 814         AC_DEFINE(HAVE_CURSES_VERSION)
 815         AC_DEFINE(HAVE_HAS_KEY)
 816         AC_DEFINE(HAVE_RESIZETERM)
 817         AC_DEFINE(HAVE_RESIZE_TERM)
 818         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
 819         AC_DEFINE(HAVE_WRESIZE)
 820         AC_DEFINE(NCURSES_EXT_FUNCS)
 821 else
 822         NCURSES_EXT_FUNCS=0
 823 fi
 824 AC_SUBST(NCURSES_EXT_FUNCS)
 825
 826 ###   use option --enable-const to turn on use of const beyond that in XSI.
 827 AC_MSG_CHECKING(for extended use of const keyword)
 828 AC_ARG_ENABLE(const,
 829         [  --enable-const          compile with extra/non-standard const],
 830         [with_ext_const=$enableval],
 831         [with_ext_const=no])
 832 AC_MSG_RESULT($with_ext_const)
 833 NCURSES_CONST='/*nothing*/'
 834 if test "$with_ext_const" = yes ; then
 835         NCURSES_CONST=const
 836 fi
 837 AC_SUBST(NCURSES_CONST)
 838
 839 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
 840 AC_ARG_ENABLE(no-padding,
 841         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
 842         [with_no_padding=$enableval],
 843         [with_no_padding=$with_ext_funcs])
 844 AC_MSG_RESULT($with_no_padding)
 845 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
 846
 847 AC_CHECK_SIZEOF([signed char], 0)
 848 if test "$ac_cv_sizeof_signed_char" = 1 ; then
 849         NCURSES_SBOOL="signed char"
 850 else
 851         NCURSES_SBOOL="char"
 852 fi
 853 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
 854 AC_ARG_ENABLE(signed-char,
 855         [  --enable-signed-char    compile using signed Boolean's in term.h],
 856         [with_signed_char=$enableval],
 857         [with_signed_char=no])
 858 AC_MSG_RESULT($with_signed_char)
 859 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
 860 AC_SUBST(NCURSES_SBOOL)
 861
 862 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
 863 AC_MSG_CHECKING(if you want SIGWINCH handler)
 864 AC_ARG_ENABLE(sigwinch,
 865         [  --enable-sigwinch       compile with SIGWINCH handler],
 866         [with_sigwinch=$enableval],
 867         [with_sigwinch=$with_ext_funcs])
 868 AC_MSG_RESULT($with_sigwinch)
 869 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
 870
 871 ###   use option --enable-tcap-names to allow user to define new capabilities
 872 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
 873 AC_ARG_ENABLE(tcap-names,
 874         [  --enable-tcap-names     compile with user-definable terminal capabilities],
 875         [with_tcap_names=$enableval],
 876         [with_tcap_names=$with_ext_funcs])
 877 AC_MSG_RESULT($with_tcap_names)
 878 NCURSES_XNAMES=0
 879 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
 880 AC_SUBST(NCURSES_XNAMES)
 881
 882 ###############################################################################
 883 # These options are relatively safe to experiment with.
 884 CF_HELP_MESSAGE(Development Code:)
 885 AC_MSG_CHECKING(if you want all development code)
 886 AC_ARG_WITH(develop,
 887         [  --without-develop       disable development options],
 888         [with_develop=$withval],
 889         [with_develop=no])
 890 AC_MSG_RESULT($with_develop)
 891
 892 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
 893 AC_MSG_CHECKING(if you want hard-tabs code)
 894 AC_ARG_ENABLE(hard-tabs,
 895         [  --enable-hard-tabs      compile with hard-tabs code],,
 896         [enable_hard_tabs=$with_develop])
 897 AC_MSG_RESULT($enable_hard_tabs)
 898 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
 899
 900 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
 901 AC_MSG_CHECKING(if you want limited support for xmc)
 902 AC_ARG_ENABLE(xmc-glitch,
 903         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
 904         [enable_xmc_glitch=$with_develop])
 905 AC_MSG_RESULT($enable_xmc_glitch)
 906 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
 907
 908 ###############################################################################
 909 # These are just experimental, probably should not be in a package:
 910 CF_HELP_MESSAGE(Experimental Code:)
 911
 912 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
 913 AC_ARG_ENABLE(assumed-color,
 914         [  --disable-assumed-color do not assume anything about default-colors],
 915         [with_assumed_color=$enableval],
 916         [with_assumed_color=yes])
 917 AC_MSG_RESULT($with_assumed_color)
 918 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
 919
 920 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
 921 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
 922 AC_ARG_ENABLE(hashmap,
 923         [  --disable-hashmap       compile without hashmap scrolling-optimization],
 924         [with_hashmap=$enableval],
 925         [with_hashmap=yes])
 926 AC_MSG_RESULT($with_hashmap)
 927 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
 928
 929 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
 930 AC_MSG_CHECKING(if you want colorfgbg code)
 931 AC_ARG_ENABLE(colorfgbg,
 932         [  --enable-colorfgbg      compile with $COLORFGBG code],
 933         [with_colorfgbg=$enableval],
 934         [with_colorfgbg=no])
 935 AC_MSG_RESULT($with_colorfgbg)
 936 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
 937
 938 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
 939 AC_MSG_CHECKING(if you want to use experimental extended colors)
 940 AC_ARG_ENABLE(ext-colors,
 941         [  --enable-ext-colors     compile for experimental 256-color support],
 942         [with_ext_colors=$enableval],
 943         [with_ext_colors=no])
 944 AC_MSG_RESULT($with_ext_colors)
 945 NCURSES_EXT_COLORS=0
 946 if test "$with_ext_colors" = yes ; then
 947         if test "$with_widec" != yes ; then
 948                 AC_MSG_ERROR(This option applies only to wide-character library)
 949         else
 950                 # cannot be ABI 5 since it changes sizeof(cchar_t)
 951                 CF_NCURSES_ABI_6
 952         fi
 953         NCURSES_EXT_COLORS=1
 954         AC_DEFINE(NCURSES_EXT_COLORS)
 955 fi
 956 AC_SUBST(NCURSES_EXT_COLORS)
 957
 958 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
 959 AC_MSG_CHECKING(if you want to use experimental extended mouse encoding)
 960 AC_ARG_ENABLE(ext-mouse,
 961         [  --enable-ext-mouse      compile for experimental mouse-encoding],
 962         [with_ext_mouse=$enableval],
 963         [with_ext_mouse=no])
 964 AC_MSG_RESULT($with_ext_mouse)
 965 NCURSES_MOUSE_VERSION=1
 966 if test "$with_ext_mouse" = yes ; then
 967         NCURSES_MOUSE_VERSION=2
 968         CF_NCURSES_ABI_6
 969 fi
 970 AC_SUBST(NCURSES_MOUSE_VERSION)
 971
 972 # This is still experimental (20080329), but should ultimately be moved to
 973 # the script-block --with-normal, etc.
 974 CF_WITH_PTHREAD
 975 if test "$with_pthread" = "yes" ; then
 976     AC_DEFINE(USE_PTHREADS)
 977     enable_reentrant=yes
 978 fi
 979
 980 # Reentrant code has to be opaque; there's little advantage to making ncurses
 981 # opaque outside of that, so there is no --enable-opaque option.  We can use
 982 # this option without --with-pthreads, but this will be always set for
 983 # pthreads.
 984 AC_MSG_CHECKING(if you want experimental reentrant code)
 985 AC_ARG_ENABLE(reentrant,
 986         [  --enable-reentrant      compile with experimental reentrant code],
 987         [with_reentrant=$enableval],
 988         [with_reentrant=no])
 989 AC_MSG_RESULT($with_reentrant)
 990 if test "$with_reentrant" = yes ; then
 991         cf_cv_enable_reentrant=1
 992         cf_cv_enable_opaque="NCURSES_INTERNALS"
 993         NCURSES_OPAQUE=1
 994         NCURSES_SIZE_T=int
 995         LIB_SUFFIX="t${LIB_SUFFIX}"
 996         AC_DEFINE(USE_REENTRANT)
 997         CF_NCURSES_ABI_6
 998 else
 999         cf_cv_enable_reentrant=0
1000         cf_cv_enable_opaque="NCURSES_OPAQUE"
1001         NCURSES_OPAQUE=0
1002         NCURSES_SIZE_T=short
1003 fi
1004 AC_SUBST(cf_cv_enable_reentrant)
1005 AC_SUBST(cf_cv_enable_opaque)
1006 AC_SUBST(NCURSES_OPAQUE)
1007 AC_SUBST(NCURSES_SIZE_T)
1008
1009 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1010 AC_ARG_ENABLE(safe-sprintf,
1011         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1012         [with_safe_sprintf=$enableval],
1013         [with_safe_sprintf=no])
1014 AC_MSG_RESULT($with_safe_sprintf)
1015 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1016
1017 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1018 # when hashmap is used scroll hints are useless
1019 if test "$with_hashmap" = no ; then
1020 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1021 AC_ARG_ENABLE(scroll-hints,
1022         [  --disable-scroll-hints  compile without scroll-hints code],
1023         [with_scroll_hints=$enableval],
1024         [with_scroll_hints=yes])
1025 AC_MSG_RESULT($with_scroll_hints)
1026 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1027 fi
1028
1029 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1030 AC_ARG_ENABLE(wgetch-events,
1031         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1032         [with_wgetch_events=$enableval],
1033         [with_wgetch_events=no])
1034 AC_MSG_RESULT($with_wgetch_events)
1035 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1036
1037 ###############################################################################
1038 CF_HELP_MESSAGE(Testing/development Options:)
1039
1040 ###     use option --disable-echo to suppress full display compiling commands
1041 AC_MSG_CHECKING(if you want to display full commands during build)
1042 AC_ARG_ENABLE(echo,
1043         [  --enable-echo           build: display "compiling" commands (default)],
1044         [with_echo=$enableval],
1045         [with_echo=yes])
1046 if test "$with_echo" = yes; then
1047         ECHO_LINK=
1048 else
1049         ECHO_LINK='@ echo linking $@ ... ;'
1050         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1051         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1052 fi
1053 AC_MSG_RESULT($with_echo)
1054 AC_SUBST(ECHO_LINK)
1055
1056 ###     use option --enable-warnings to turn on all gcc warnings
1057 AC_MSG_CHECKING(if you want to see compiler warnings)
1058 AC_ARG_ENABLE(warnings,
1059         [  --enable-warnings       build: turn on GCC compiler warnings],
1060         [with_warnings=$enableval])
1061 AC_MSG_RESULT($with_warnings)
1062
1063 if test "x$with_warnings" = "xyes"; then
1064         ADAFLAGS="$ADAFLAGS -gnatg"
1065         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1066         if test "$cf_with_cxx" = yes ; then
1067                 CF_GXX_WARNINGS(Wno-unused)
1068         fi
1069 fi
1070 CF_GCC_ATTRIBUTES
1071
1072 ###     use option --enable-assertions to turn on generation of assertion code
1073 AC_MSG_CHECKING(if you want to enable runtime assertions)
1074 AC_ARG_ENABLE(assertions,
1075         [  --enable-assertions     test: turn on generation of assertion code],
1076         [with_assertions=$enableval],
1077         [with_assertions=no])
1078 AC_MSG_RESULT($with_assertions)
1079 if test -n "$GCC"
1080 then
1081         if test "$with_assertions" = no
1082         then
1083                 AC_DEFINE(NDEBUG)
1084                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1085         else
1086                 ADAFLAGS="$ADAFLAGS -gnata"
1087         fi
1088 fi
1089
1090 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1091 CF_DISABLE_LEAKS
1092 AC_DEFINE(HAVE_NC_ALLOC_H)
1093
1094 ###     use option --enable-expanded to generate certain macros as functions
1095 AC_ARG_ENABLE(expanded,
1096         [  --enable-expanded       test: generate functions for certain macros],
1097         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1098
1099 ###     use option --disable-macros to suppress macros in favor of functions
1100 AC_ARG_ENABLE(macros,
1101         [  --disable-macros        test: use functions rather than macros],
1102         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1103
1104 # Normally we only add trace() to the debug-library.  Allow this to be
1105 # extended to all models of the ncurses library:
1106 cf_all_traces=no
1107 case "$CFLAGS $CPPFLAGS" in
1108 *-DTRACE*)
1109         cf_all_traces=yes
1110         ;;
1111 esac
1112
1113 AC_MSG_CHECKING(whether to add trace feature to all models)
1114 AC_ARG_WITH(trace,
1115 [  --with-trace            test: add trace() function to all models of ncurses],
1116 [cf_with_trace=$withval],
1117 [cf_with_trace=$cf_all_traces])
1118 AC_MSG_RESULT($cf_with_trace)
1119
1120 if test "$cf_with_trace" = yes ; then
1121         LIB_TRACING=all
1122         ADA_TRACE=TRUE
1123         CF_ADD_CFLAGS(-DTRACE)
1124 else
1125         LIB_TRACING=DEBUG
1126         ADA_TRACE=FALSE
1127 fi
1128
1129 AC_SUBST(ADA_TRACE)
1130
1131 ###     Checks for libraries.
1132 AC_CHECK_FUNC(gettimeofday,
1133         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1134
1135 AC_CHECK_LIB(bsd, gettimeofday,
1136         AC_DEFINE(HAVE_GETTIMEOFDAY)
1137         LIBS="$LIBS -lbsd")])dnl CLIX: bzero, select, gettimeofday
1138
1139 CF_MATH_LIB(MATH_LIB,sin(x))
1140 AC_SUBST(MATH_LIB)
1141
1142 ###     Checks for header files.
1143 AC_STDC_HEADERS
1144 AC_HEADER_DIRENT
1145 AC_HEADER_TIME
1146 CF_REGEX
1147
1148 dnl These are some other potentially nonportable headers.
1149 AC_CHECK_HEADERS( \
1150 fcntl.h \
1151 getopt.h \
1152 limits.h \
1153 locale.h \
1154 poll.h \
1155 sys/bsdtypes.h \
1156 sys/ioctl.h \
1157 sys/param.h \
1158 sys/poll.h \
1159 sys/select.h \
1160 sys/time.h \
1161 sys/times.h \
1162 ttyent.h \
1163 unistd.h \
1164 wctype.h \
1165 )
1166
1167 # check for ISC (this may also define _POSIX_SOURCE)
1168 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1169 if test "$ISC" = yes ; then
1170         AC_CHECK_LIB(cposix,main)
1171         AC_CHECK_LIB(inet,bzero,LIBS="$LIBS -linet")dnl also 'select()'
1172 fi
1173
1174 CF_SYS_TIME_SELECT
1175
1176 ###     checks for compiler characteristics
1177 AC_LANG_C
1178 AC_C_CONST
1179 CF_C_INLINE(NCURSES_INLINE,1200)
1180 CF_SIG_ATOMIC_T
1181
1182 if test $NCURSES_CHTYPE = auto ; then
1183         CF_TYPEOF_CHTYPE
1184 else
1185         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1186 fi
1187 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1188 AC_SUBST(cf_cv_typeof_chtype)
1189
1190 CF_UNSIGNED_LITERALS
1191 cf_cv_1UL="1"
1192 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1193 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1194 AC_SUBST(cf_cv_1UL)
1195
1196 if test $NCURSES_MMASK_T = auto ; then
1197         cf_cv_typeof_mmask_t=long
1198 else
1199         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1200 fi
1201 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1202 AC_SUBST(cf_cv_typeof_mmask_t)
1203
1204 ###     Checks for external-data
1205 CF_ERRNO
1206 CF_LINK_DATAONLY
1207
1208 ###     Checks for library functions.
1209 AC_CHECK_FUNCS( \
1210 getcwd \
1211 getegid \
1212 geteuid \
1213 getttynam \
1214 issetugid \
1215 poll \
1216 remove \
1217 select \
1218 setbuf \
1219 setbuffer \
1220 setvbuf \
1221 sigaction \
1222 sigvec \
1223 strdup \
1224 strstr \
1225 tcgetpgrp \
1226 times \
1227 vsnprintf \
1228 )
1229 if test "$with_getcap" = "yes" ; then
1230         CF_CGETENT
1231 fi
1232
1233 CF_ISASCII
1234 CF_STRUCT_SIGACTION
1235 CF_FUNC_NANOSLEEP
1236 CF_FUNC_TERMIOS
1237 CF_FUNC_VSSCANF
1238 CF_MKSTEMP
1239
1240 # setup for prototype of fallback for vsscanf()
1241 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1242
1243 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1244 if test "$cross_compiling" = yes ; then
1245         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1246 else
1247         AC_FUNC_SETVBUF_REVERSED
1248 fi
1249 AC_TYPE_SIGNAL
1250 CF_TYPE_SIGACTION
1251 CF_SIZECHANGE
1252 CF_FUNC_MEMMOVE
1253 CF_FUNC_POLL
1254
1255 if test "$with_hashed_db" != no ; then
1256         AC_DEFINE(USE_HASHED_DB)
1257         CF_HASHED_DB($with_hashed_db)
1258 fi
1259
1260 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1261 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1262         CF_STRIP_G_OPT(CFLAGS)
1263         CF_STRIP_G_OPT(CXXFLAGS)
1264 fi
1265
1266 # Just in case, check if the C compiler has a bool type.
1267 CF_BOOL_DECL(cf_cv_cc_bool_type)
1268
1269 # Check for C++ compiler characteristics (and ensure that it's there!)
1270 if test -n "$CXX" ; then
1271         AC_LANG_CPLUSPLUS
1272         CF_STDCPP_LIBRARY
1273         CF_PROG_CC_C_O(CXX)
1274
1275         case $GXX_VERSION in
1276         1*|2.[0-6]*)
1277                 cf_cxx_library=yes
1278                 ;;
1279         *-2.7*|2.7*)
1280                 CF_GPP_LIBRARY
1281                 ;;
1282         *)
1283                 cf_cxx_library=no
1284                 ;;
1285         esac
1286
1287         AC_CHECK_HEADERS(iostream typeinfo)
1288
1289         CF_BOOL_DECL
1290         CF_BOOL_SIZE
1291         CF_ETIP_DEFINES
1292         CF_CPP_PARAM_INIT
1293         CF_CPP_STATIC_CAST
1294
1295         CXX_AR='$(AR)'
1296         CXX_AR_OPTS='$(AR_OPTS)'
1297         case $cf_cv_system_name in #(vi
1298         irix*) #(vi
1299             if test "$GXX" != yes ; then
1300                 CXX_AR='$(CXX)'
1301                 CXX_AR_OPTS='-ar -o'
1302             fi
1303             ;;
1304         sco3.2v5*) #(vi
1305             CXXLDFLAGS="-u main"
1306             ;;
1307         solaris2*)
1308             if test "$GXX" != yes ; then
1309                 CXX_AR='$(CXX)'
1310                 CXX_AR_OPTS='-xar -o'
1311             fi
1312             ;;
1313         esac
1314         AC_SUBST(CXXLDFLAGS)
1315         AC_SUBST(CXX_AR)
1316         AC_SUBST(CXX_AR_OPTS)
1317 else
1318         cf_cxx_library=no
1319         cf_cv_builtin_bool=1
1320
1321         # Just because we are not configuring against C++ right now does not
1322         # mean that a user will not want to use C++.  Some distributors disable
1323         # the C++ portion of this configuration as a shortcut (or just to avoid
1324         # compiling the demo in the c++ directory).  So we need a reasonable
1325         # default for the 'bool' type.
1326         #
1327         # Caveat: since the storage of the bool type is not standardized, it
1328         # may change.
1329
1330         if test "$NCURSES_BOOL" != auto ; then
1331                 cf_cv_type_of_bool=$NCURSES_BOOL
1332                 cf_cv_header_stdbool_h=0
1333         else
1334                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1335                         CF_BOOL_SIZE
1336                 else
1337                         AC_MSG_CHECKING(for fallback type of bool)
1338                         case "$host_cpu" in #(vi
1339                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1340                         *)      cf_cv_type_of_bool=int  ;;
1341                         esac
1342                         AC_MSG_RESULT($cf_cv_type_of_bool)
1343                 fi
1344         fi
1345 fi
1346 AC_SUBST(CXXLIBS)
1347
1348 # If the C compiler did not declare bool, and we did not determine that the C++
1349 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1350 # ncurses library use the same type as C++ bool.  Note that this allows one to
1351 # specify the type of bool in a configure-script option and postpone
1352 # integration with the C++ compiler provided that the types are compatible.
1353 USE_CXX_BOOL=1
1354 if test $cf_cv_cc_bool_type = 1
1355 then
1356         # oops: C has a bool.  Unlikely, but C++ could differ.
1357         USE_CXX_BOOL=0
1358 elif test $cf_cv_builtin_bool = 0
1359 then
1360         # C++ has no bool
1361         USE_CXX_BOOL=0
1362 else
1363         # this is the normal case
1364         USE_CXX_BOOL='defined(__cplusplus)'
1365 fi
1366 AC_SUBST(USE_CXX_BOOL)
1367
1368 CF_HELP_MESSAGE(Ada95 Binding Options:)
1369
1370 dnl If the Ada95 source-tree is present, add that to the build unless it will
1371 dnl not work, or was not requested.
1372 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1373
1374 dnl libtool does not know anything about GNAT, though a change made in 1998
1375 dnl provided for it "someday".  Disable the ada subtree if we are using
1376 dnl libtool -TD 20070714
1377 if test "$cf_with_ada" != "no" ; then
1378     if test "$with_libtool" != "no"; then
1379         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1380         cf_with_ada=no
1381     fi
1382 fi
1383
1384 dnl Check for availability of GNU Ada Translator (GNAT).
1385 dnl At the moment we support no other Ada95 compiler.
1386 if test "$cf_with_ada" != "no" ; then
1387 cf_ada_make=gnatmake
1388 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
1389 if test "$ac_cv_prog_gnat_exists" = no; then
1390    cf_ada_make=
1391 else
1392    CF_GNAT_VERSION
1393    AC_CHECK_PROG(M4_exists, m4, yes, no)
1394    if test "$ac_cv_prog_M4_exists" = no; then
1395       cf_cv_prog_gnat_correct=no
1396       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
1397    fi
1398    if test "$cf_cv_prog_gnat_correct" = yes; then
1399       AC_MSG_CHECKING(if GNAT works)
1400       CF_GNAT_TRY_RUN([procedure conftest;],
1401 [with Text_IO;
1402 with GNAT.OS_Lib;
1403 procedure conftest is
1404 begin
1405    Text_IO.Put ("Hello World");
1406    Text_IO.New_Line;
1407    GNAT.OS_Lib.OS_Exit (0);
1408 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
1409       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
1410    fi
1411 fi
1412 if test "$cf_cv_prog_gnat_correct" = yes; then
1413    ADAFLAGS="-O3 -gnatpn $ADAFLAGS"
1414
1415    AC_MSG_CHECKING(if GNAT pragma Unreferenced works)
1416    CF_GNAT_TRY_LINK([procedure conftest;],
1417 [with Text_IO;
1418 with GNAT.OS_Lib;
1419 procedure conftest is
1420    test : Integer;
1421    pragma Unreferenced (test);
1422 begin
1423    test := 1;
1424    Text_IO.Put ("Hello World");
1425    Text_IO.New_Line;
1426    GNAT.OS_Lib.OS_Exit (0);
1427 end conftest;],[cf_cv_pragma_unreferenced=yes],[cf_cv_pragma_unreferenced=no])
1428    AC_MSG_RESULT($cf_cv_pragma_unreferenced)
1429
1430    # if the pragma is supported, use it (needed in the Trace code).
1431    if test $cf_cv_pragma_unreferenced = yes ; then
1432       PRAGMA_UNREF=TRUE
1433    else
1434       PRAGMA_UNREF=FALSE
1435    fi
1436
1437    AC_ARG_WITH(ada-compiler,
1438         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
1439         [cf_ada_compiler=$withval],
1440         [cf_ada_compiler=gnatmake])
1441
1442    cf_ada_package=terminal_interface
1443
1444    AC_SUBST(cf_ada_make)
1445    AC_SUBST(cf_ada_compiler)
1446    AC_SUBST(cf_ada_package)
1447    AC_SUBST(ADAFLAGS)
1448    AC_SUBST(cf_compile_generics)
1449    AC_SUBST(cf_generic_objects)
1450    AC_SUBST(PRAGMA_UNREF)
1451
1452    CF_WITH_PATH(ada-include,
1453        [  --with-ada-include=DIR  Ada includes are in DIR],
1454        ADA_INCLUDE,
1455        PREFIX/lib/ada/adainclude,
1456        [$]prefix/lib/ada/adainclude)
1457    AC_SUBST(ADA_INCLUDE)
1458
1459    CF_WITH_PATH(ada-objects,
1460        [  --with-ada-objects=DIR  Ada objects are in DIR],
1461        ADA_OBJECTS,
1462        PREFIX/lib/ada/adalib,
1463        [$]prefix/lib/ada/adalib)
1464    AC_SUBST(ADA_OBJECTS)
1465
1466 fi
1467 fi
1468 else
1469    cf_with_ada=no
1470 fi
1471
1472 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1473 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1474 ###
1475 ### ticlib modules may be a separate library, otherwise contained in termlib.
1476 ### termlib modules may be a separate library, otherwise contained in ncurses.
1477 ###
1478 ### The of "+" or " " between the tokens controls the way the script
1479 ### chooses to split module lists into libraries.
1480 ###
1481 ### (see CF_LIB_RULES).
1482 AC_MSG_CHECKING(for library subsets)
1483 LIB_SUBSETS=
1484
1485 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1486         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1487         if test "$with_ticlib" != no ; then
1488                 LIB_SUBSETS="${LIB_SUBSETS} "
1489         else
1490                 LIB_SUBSETS="${LIB_SUBSETS}+"
1491         fi
1492 fi
1493
1494 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1495 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1496 if test "$with_termlib" != no ; then
1497         LIB_SUBSETS="${LIB_SUBSETS} "
1498 else
1499         LIB_SUBSETS="${LIB_SUBSETS}+"
1500 fi
1501
1502 LIB_SUBSETS="${LIB_SUBSETS}base"
1503 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1504 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1505
1506 AC_MSG_RESULT($LIB_SUBSETS)
1507
1508 ### Construct the list of include-directories to be generated
1509 CF_INCLUDE_DIRS
1510 CF_ADA_INCLUDE_DIRS
1511
1512 ### Build up pieces for makefile rules
1513 AC_MSG_CHECKING(default library suffix)
1514 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1515 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1516 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1517
1518 AC_MSG_CHECKING(default library-dependency suffix)
1519 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_DEP_SUFFIX)dnl
1520 DFT_LIB_SUFFIX=$DFT_DEP_SUFFIX
1521 if test $DFT_LWR_MODEL = shared ; then
1522         case $cf_cv_system_name in #(vi
1523         cygwin*)
1524                 DFT_DEP_SUFFIX=".dll.a"
1525                 DFT_LIB_SUFFIX=".dll"
1526                 ;;
1527         esac
1528 fi
1529 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1530 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1531
1532 AC_MSG_CHECKING(default object directory)
1533 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1534 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1535 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1536
1537 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1538 if test "$cf_with_cxx" = yes ; then
1539 AC_MSG_CHECKING(c++ library-dependency suffix)
1540 if test "$with_libtool" != "no"; then
1541         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1542 else
1543         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX)dnl we normally make a static library
1544 fi
1545 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1546 AC_SUBST(CXX_LIB_SUFFIX)
1547 fi
1548
1549 # do not want -ldl in build except as needed for -lncurses dependency
1550 if test "$with_dlsym" = yes ; then
1551 if test $DFT_LWR_MODEL = shared || \
1552    test $DFT_LWR_MODEL = libtool ; then
1553         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1554 fi
1555 fi
1556 ### Set up low-level terminfo dependencies for makefiles.
1557
1558 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1559 # do not need libdl
1560 TICS_LIST=
1561 if test "$with_dlsym" = yes ; then
1562         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1563 fi
1564
1565 if test "$with_ticlib" != no ; then
1566
1567         if test "$with_ticlib" != yes ; then
1568                 TICS_NAME=$with_ticlib
1569                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1570                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1571                 TICS_LIB_SUFFIX="${with_ticlib}"
1572         else
1573                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1574                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1575                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1576         fi
1577         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1578 else
1579         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1580 fi
1581 AC_SUBST(TICS_ARG_SUFFIX)
1582 AC_SUBST(TICS_DEP_SUFFIX)
1583 AC_SUBST(TICS_LIB_SUFFIX)
1584 AC_SUBST(TICS_ARGS)
1585
1586 if test "$with_termlib" != no ; then
1587
1588         if test "$with_termlib" != yes ; then
1589                 TINFO_NAME=$with_termlib
1590                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1591                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1592                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1593                 TINFO_LIB_SUFFIX="${with_termlib}"
1594         else
1595                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1596                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1597                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1598                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1599         fi
1600
1601         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1602         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1603         if test "$DFT_LWR_MODEL" = "libtool"; then
1604                 TEST_ARGS="${TEST_DEPS}"
1605                 TEST_ARG2="${TEST_DEP2}"
1606                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1607         else
1608                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1609                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1610                 TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1611                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1612                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1613         fi
1614 else
1615         # the next lines are needed for linking libtic over libncurses
1616         TINFO_NAME=${LIB_NAME}
1617         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1618         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1619         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1620
1621         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1622 fi
1623
1624 if test "$DFT_LWR_MODEL" = shared ; then
1625         case $cf_cv_system_name in #(vi
1626         cygwin*)
1627                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1628                 TINFO_SUFFIX=.dll
1629                 ;;
1630         esac
1631 fi
1632
1633 AC_SUBST(TINFO_ARG_SUFFIX)
1634 AC_SUBST(TINFO_DEP_SUFFIX)
1635 AC_SUBST(TINFO_LIB_SUFFIX)
1636 AC_SUBST(TINFO_ARGS)
1637
1638 if test "$with_dlsym" = yes ; then
1639         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1640 fi
1641
1642 if test "$DFT_LWR_MODEL" = "libtool"; then
1643     OBJEXT=lo
1644 fi
1645
1646 # needed for Ada95
1647 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1648 AC_SUBST(TINFO_ARGS2)
1649
1650 case $DFT_LWR_MODEL in
1651 normal|debug|profile)
1652         CF_LDFLAGS_STATIC
1653         ;;
1654 esac
1655
1656 AC_MSG_CHECKING(where we will install curses.h)
1657 test "$with_overwrite" = no && \
1658 test "x$includedir" = 'x${prefix}/include' && \
1659         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1660 AC_MSG_RESULT($includedir)
1661
1662 ### Resolve a conflict between normal and wide-curses by forcing applications
1663 ### that will need libutf8 to add it to their configure script.
1664 if test "$with_overwrite" != no ; then
1665 if test "$NCURSES_LIBUTF8" = 1 ; then
1666         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1667         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1668 fi
1669 fi
1670
1671 AC_SUBST(WITH_OVERWRITE)
1672 AC_SUBST(TICS_LIST)
1673 AC_SUBST(TINFO_LIST)
1674 AC_SUBST(SHLIB_LIST)
1675
1676 # used to separate tack out of the tree
1677 NCURSES_TREE=
1678 AC_SUBST(NCURSES_TREE)
1679
1680 ### predefined stuff for the test programs
1681 AC_DEFINE(HAVE_SLK_COLOR)
1682
1683 ### Construct the list of subdirectories for which we'll customize makefiles
1684 ### with the appropriate compile-rules.
1685
1686 CF_SRC_MODULES($modules_to_build)
1687
1688 if test "$cf_with_ada" != "no" && test "$cf_cv_prog_gnat_correct" != "no"; then
1689    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses-config"
1690 fi
1691
1692 CF_DIRS_TO_MAKE
1693
1694 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATHSEP')
1695
1696 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1697
1698 ### Now that we're done running tests, add the compiler-warnings, if any
1699 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1700
1701 ### If we're building with rpath, try to link non-standard libs that way too.
1702 if test "$DFT_LWR_MODEL" = "shared"; then
1703   CF_RPATH_HACK
1704 fi
1705
1706 ### Define substitutions for header files to avoid name-pollution
1707 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1708 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1709 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1710
1711 ################################################################################
1712 test "$use_database" = yes && SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1713 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1714 AC_OUTPUT( \
1715         include/MKterm.h.awk \
1716         include/curses.head:include/curses.h.in \
1717         include/termcap.h \
1718         include/unctrl.h \
1719         $SUB_MAKEFILES \
1720         Makefile,[
1721 CF_PRG_RULES([$srcdir/test/mk-test.awk ECHO_LINK="$ECHO_LINK"], test)
1722 CF_LIB_RULES($SRC_SUBDIRS)
1723 ],[
1724 ### Special initialization commands, used to pass information from the
1725 ### configuration-run into config.status
1726
1727 AWK="$AWK"
1728 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1729 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1730 ECHO_LINK="$ECHO_LINK"
1731 LDCONFIG="$LDCONFIG"
1732 LIB_NAME="$LIB_NAME"
1733 LIB_SUBSETS="$LIB_SUBSETS"
1734 LIB_SUFFIX="$LIB_SUFFIX"
1735 LIB_TRACING="$LIB_TRACING"
1736 MAKE_TERMINFO="$MAKE_TERMINFO"
1737 NCURSES_MAJOR="$NCURSES_MAJOR"
1738 NCURSES_MINOR="$NCURSES_MINOR"
1739 NCURSES_OSPEED="$NCURSES_OSPEED"
1740 NCURSES_PATCH="$NCURSES_PATCH"
1741 SRC_SUBDIRS="$SRC_SUBDIRS"
1742 TERMINFO="$TERMINFO"
1743 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1744 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1745 TINFO_NAME="$TINFO_NAME"
1746 TINFO_SUFFIX="$TINFO_SUFFIX"
1747 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1748 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1749 TICS_NAME="$TICS_NAME"
1750 WITH_CURSES_H="$with_curses_h"
1751 WITH_ECHO="$with_echo"
1752 WITH_OVERWRITE="$with_overwrite"
1753 cf_LIST_MODELS="$cf_list_models"
1754 cf_cv_abi_version="$cf_cv_abi_version"
1755 cf_cv_do_relink="$cf_cv_do_relink"
1756 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1757 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1758 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1759 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1760 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1761 cf_cv_rel_version="$cf_cv_rel_version"
1762 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1763 cf_cv_shlib_version="$cf_cv_shlib_version"
1764 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1765 cf_cv_system_name="$cf_cv_system_name"
1766 cf_with_cxx_binding="$cf_with_cxx_binding"
1767 host="$host"
1768 target="$target"
1769
1770 ],cat)dnl
1771 ${MAKE-make} preinstall