ncurses 5.7 - patch 20100313
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2009,2010 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: configure.in,v 1.487 2010/03/06 21:29:37 tom Exp $
32 dnl Process this file with autoconf to produce a configure script.
33 dnl
34 dnl See http://invisible-island.net/autoconf/ for additional information.
35 dnl
36 dnl ---------------------------------------------------------------------------
37 AC_PREREQ(2.13.20020210)
38 AC_REVISION($Revision: 1.487 $)
39 AC_INIT(ncurses/base/lib_initscr.c)
40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
41
42 CF_TOP_BUILDDIR
43 CF_SUBST_NCURSES_VERSION
44
45 CF_WITH_REL_VERSION(NCURSES)
46 CF_WITH_ABI_VERSION
47
48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
49 AC_ARG_WITH(system-type,
50 [  --with-system-type=XXX  test: override derived host system-type],
51 [AC_MSG_WARN(overriding system type to $withval)
52  cf_cv_system_name=$withval])
53
54 ###     Save the given $CFLAGS to allow user-override.
55 cf_user_CFLAGS="$CFLAGS"
56
57 ###     Default install-location
58 CF_CFG_DEFAULTS
59
60 ###     Checks for programs.
61 AC_PROG_CC
62 CF_GCC_VERSION
63
64 AC_PROG_CPP
65 AC_PROG_GCC_TRADITIONAL
66 CF_PROG_CC_C_O(CC)
67 AC_ISC_POSIX
68 CF_ANSI_CC_REQD
69 CF_PROG_EXT
70 CF_PROG_LDCONFIG
71
72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
73 dnl                             configure script by not letting us test if C++
74 dnl                             is present, making this option necessary.
75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
76 AC_ARG_WITH(cxx,
77         [  --without-cxx           do not adjust ncurses bool to match C++],
78         [cf_with_cxx=$withval],
79         [cf_with_cxx=yes])
80 AC_MSG_RESULT($cf_with_cxx)
81 if test "X$cf_with_cxx" = Xno ; then
82         CXX=""
83         GXX=""
84 else
85         # with autoconf 2.13, we can change the error to a warning:
86         pushdef([AC_MSG_ERROR],
87                 [AC_MSG_RESULT(no)
88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
90         AC_PROG_CXX
91         popdef([AC_MSG_ERROR])dnl
92         # autoconf 2.5x removed the error - by hardcoding it to g++.
93         if test "$CXX" = "g++" ; then
94                 AC_PATH_PROG(CXX,g++)
95         fi
96         if test "$CXX" = "g++" ; then
97                 AC_MSG_WARN(ignoring hardcoded g++)
98                 cf_with_cxx=no; CXX=""; GXX="";
99         fi
100 fi
101
102 CF_GXX_VERSION
103 case $GXX_VERSION in
104 1*|2.[[0-6]]*)
105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
106         # cf_cxx_library=no
107         AC_MSG_WARN(templates do not work)
108         ;;
109 esac
110
111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
112 AC_ARG_WITH(cxx-binding,
113         [  --without-cxx-binding   do not build C++ binding and demo],
114         [cf_with_cxx_binding=$withval],
115         [cf_with_cxx_binding=$cf_with_cxx])
116 AC_MSG_RESULT($cf_with_cxx_binding)
117
118 AC_MSG_CHECKING(if you want to build with Ada95)
119 AC_ARG_WITH(ada,
120         [  --without-ada           suppress check for Ada95, don't build demo],
121         [cf_with_ada=$withval],
122         [cf_with_ada=yes])
123 AC_MSG_RESULT($cf_with_ada)
124
125 AC_MSG_CHECKING(if you want to install manpages)
126 AC_ARG_WITH(manpages,
127         [  --without-manpages      suppress install of manpages],
128         [cf_with_manpages=$withval],
129         [cf_with_manpages=yes])
130 AC_MSG_RESULT($cf_with_manpages)
131
132 AC_MSG_CHECKING(if you want to build programs such as tic)
133 AC_ARG_WITH(progs,
134         [  --without-progs         suppress build with programs (e.g., tic)],
135         [cf_with_progs=$withval],
136         [cf_with_progs=yes])
137 AC_MSG_RESULT($cf_with_progs)
138
139 AC_MSG_CHECKING(if you wish to install curses.h)
140 AC_ARG_WITH(curses-h,
141         [  --without-curses-h      install curses.h as ncurses.h only],
142         [with_curses_h=$withval],
143         [with_curses_h=yes])
144 AC_MSG_RESULT($with_curses_h)
145
146 modules_to_build="ncurses"
147 if test "X$cf_with_progs" != Xno ; then
148 modules_to_build="$modules_to_build progs tack"
149 fi
150 modules_to_build="$modules_to_build panel menu form"
151
152 AC_ARG_PROGRAM
153
154 CF_PROG_AWK
155 CF_PROG_EGREP
156 CF_PROG_INSTALL
157 CF_PROG_LINT
158 AC_PROG_LN_S
159
160 AC_SYS_LONG_FILE_NAMES
161
162 # if we find pkg-config, check if we should install the ".pc" files.
163 CF_PKG_CONFIG
164
165 if test "$PKG_CONFIG" != no ; then
166         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
167
168         # Leave this as something that can be overridden in the environment.
169         if test -z "$PKG_CONFIG_LIBDIR" ; then
170                 PKG_CONFIG_LIBDIR=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`/lib/pkgconfig
171         fi
172         PKG_CONFIG_LIBDIR=`echo "$PKG_CONFIG_LIBDIR" | sed -e 's/^://' -e 's/:.*//'`
173         if test -n "$PKG_CONFIG_LIBDIR" && test -d "$PKG_CONFIG_LIBDIR" ; then
174                 AC_ARG_ENABLE(pc-files,
175                         [  --enable-pc-files       generate and install .pc files for pkg-config],
176                         [enable_pc_files=$enableval],
177                         [enable_pc_files=no])
178                 AC_MSG_RESULT($enable_pc_files)
179         else
180                 AC_MSG_RESULT(no)
181                 AC_MSG_WARN(did not find library $PKG_CONFIG_LIBDIR)
182                 enable_pc_files=no
183         fi
184 fi
185 AC_SUBST(PKG_CONFIG_LIBDIR)
186
187 AC_MSG_CHECKING(if we should assume mixed-case filenames)
188 AC_ARG_ENABLE(mixed-case,
189         [  --enable-mixed-case     tic should assume mixed-case filenames],
190         [enable_mixedcase=$enableval],
191         [enable_mixedcase=auto])
192 AC_MSG_RESULT($enable_mixedcase)
193 if test "$enable_mixedcase" = "auto" ; then
194     CF_MIXEDCASE_FILENAMES
195 else
196     cf_cv_mixedcase=$enable_mixedcase
197     if test "$enable_mixedcase" = "yes" ; then
198         AC_DEFINE(MIXEDCASE_FILENAMES)
199     fi
200 fi
201
202 # do this after mixed-case option (tags/TAGS is not as important as tic).
203 AC_PROG_MAKE_SET
204 CF_MAKE_TAGS
205 CF_MAKEFLAGS
206
207 dnl These are standard among *NIX systems, but not when cross-compiling
208 AC_CHECK_TOOL(RANLIB, ranlib, ':')
209 AC_CHECK_TOOL(LD, ld, ld)
210 AC_CHECK_TOOL(AR, ar, ar)
211 CF_AR_FLAGS
212
213 dnl Special option for use by system-builders: the install-prefix is used to
214 dnl adjust the location into which the actual install is done, so that an
215 dnl archive can be built without modifying the host system's configuration.
216 AC_MSG_CHECKING(if you have specified an install-prefix)
217 AC_ARG_WITH(install-prefix,
218         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
219         [case "$withval" in #(vi
220         yes|no) #(vi
221                 ;;
222         *)      DESTDIR="$withval"
223                 ;;
224         esac])
225 AC_MSG_RESULT($DESTDIR)
226 AC_SUBST(DESTDIR)
227
228 ###############################################################################
229 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
230 # If we're cross-compiling, allow the user to override the tools and their
231 # options.  The configure script is oriented toward identifying the host
232 # compiler, etc., but we need a build compiler to generate parts of the source.
233 CF_BUILD_CC
234
235 ###############################################################################
236 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
237
238 ### Options to allow the user to specify the set of libraries which are used.
239 ### Use "--without-normal --with-shared" to allow the default model to be
240 ### shared, for example.
241 cf_list_models=""
242 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
243
244 CF_WITH_LIBTOOL
245 if test "$with_libtool" != "no" ; then
246
247 cf_list_models="$cf_list_models libtool"
248
249 else
250
251 AC_MSG_CHECKING(if you want to build shared libraries)
252 AC_ARG_WITH(shared,
253         [  --with-shared           generate shared-libraries],
254         [with_shared=$withval],
255         [with_shared=no])
256 AC_MSG_RESULT($with_shared)
257 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
258
259 AC_MSG_CHECKING(if you want to build static libraries)
260 AC_ARG_WITH(normal,
261         [  --with-normal           generate normal-libraries (default)],
262         [with_normal=$withval],
263         [with_normal=yes])
264 AC_MSG_RESULT($with_normal)
265 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
266
267 AC_MSG_CHECKING(if you want to build debug libraries)
268 AC_ARG_WITH(debug,
269         [  --with-debug            generate debug-libraries (default)],
270         [with_debug=$withval],
271         [with_debug=yes])
272 AC_MSG_RESULT($with_debug)
273 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
274
275 AC_MSG_CHECKING(if you want to build profiling libraries)
276 AC_ARG_WITH(profile,
277         [  --with-profile          generate profile-libraries],
278         [with_profile=$withval],
279         [with_profile=no])
280 AC_MSG_RESULT($with_profile)
281 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
282
283 fi
284
285 ###############################################################################
286
287 AC_MSG_CHECKING(for specified models)
288 test -z "$cf_list_models" && cf_list_models=normal
289 dnl If we use libtool to generate libraries, then it must be the only
290 dnl specified model.
291 test "$with_libtool" != "no" && cf_list_models=libtool
292 AC_MSG_RESULT($cf_list_models)
293
294 ### Use the first model as the default, and save its suffix for use in building
295 ### up test-applications.
296 AC_MSG_CHECKING(for default model)
297 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
298 AC_MSG_RESULT($DFT_LWR_MODEL)
299
300 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
301
302 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
303 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
304
305 TICS_NAME=tic
306 AC_SUBST(TICS_NAME)
307
308 TINFO_NAME=tinfo
309 AC_SUBST(TINFO_NAME)
310
311 LIB_NAME=ncurses
312 AC_SUBST(LIB_NAME)
313
314 LIB_DIR=../lib
315 LIB_2ND=../../lib
316
317 CF_LIB_PREFIX(cf_prefix)
318 LIB_PREFIX=$cf_prefix
319 AC_SUBST(LIB_PREFIX)
320
321 LIB_SUFFIX=
322 AC_SUBST(LIB_SUFFIX)
323
324 ###############################################################################
325
326 AC_MSG_CHECKING(if you want to build a separate terminfo library)
327 AC_ARG_WITH(termlib,
328         [  --with-termlib          generate separate terminfo library],
329         [with_termlib=$withval],
330         [with_termlib=no])
331 AC_MSG_RESULT($with_termlib)
332
333 AC_MSG_CHECKING(if you want to build a separate tic library)
334 AC_ARG_WITH(ticlib,
335         [  --with-ticlib           generate separate tic library],
336         [with_ticlib=$withval],
337         [with_ticlib=no])
338 AC_MSG_RESULT($with_ticlib)
339
340 ### Checks for special libraries, must be done up-front.
341 SHLIB_LIST=""
342 CF_WITH_GPM
343 if test "$with_gpm" != no ; then
344         AC_MSG_CHECKING(if you want to load GPM dynamically)
345         AC_ARG_WITH(dlsym,
346                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
347                 [with_dlsym=$withval],
348                 [with_dlsym=yes])
349         AC_MSG_RESULT($with_dlsym)
350         if test "$with_dlsym" = yes ; then
351                 CF_FUNC_DLSYM
352                 if test "$with_gpm" != yes ; then
353                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
354                         cf_cv_gpm_soname="$with_gpm"
355                 else
356                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
357                 fi
358                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
359                 SHLIB_LIST="-ldl $SHLIB_LIST"
360         else
361                 SHLIB_LIST="-lgpm $SHLIB_LIST"
362                 TEST_LIBS="-lgpm $TEST_LIBS"
363         fi
364         AC_DEFINE(HAVE_LIBGPM)
365         CF_CHECK_GPM_WGETCH
366 fi
367
368 CF_WITH_SYSMOUSE
369
370 dnl Not all ports of gcc support the -g option
371
372 if test X"$CC_G_OPT" = X"" ; then
373         CC_G_OPT='-g'
374         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
375 fi
376 AC_SUBST(CC_G_OPT)
377
378 if test X"$CXX_G_OPT" = X"" ; then
379         CXX_G_OPT='-g'
380         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
381 fi
382 AC_SUBST(CXX_G_OPT)
383
384 AC_MSG_CHECKING(for default loader flags)
385 case $DFT_LWR_MODEL in
386 libtool) LD_MODEL=''   ;;
387 normal)  LD_MODEL=''   ;;
388 debug)   LD_MODEL=$CC_G_OPT ;;
389 profile) LD_MODEL='-pg';;
390 shared)  LD_MODEL=''   ;;
391 esac
392 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
393 AC_MSG_RESULT($LD_MODEL)
394
395 case $DFT_LWR_MODEL in
396 shared)
397 CF_ENABLE_RPATH
398 AC_MSG_CHECKING(if shared libraries should be relinked during install)
399 AC_ARG_ENABLE(relink,
400 [  --disable-relink        relink shared libraries during install],
401 [cf_cv_do_relink=$enableval],
402 [cf_cv_do_relink=yes])
403 AC_MSG_RESULT($cf_cv_do_relink)
404         ;;
405 esac
406
407 CF_SHARED_OPTS
408 if test "$CC_SHARED_OPTS" = "unknown"; then
409         for model in $cf_list_models; do
410                 if test "$model" = "shared"; then
411                         AC_ERROR(Shared libraries are not supported in this version)
412                 fi
413         done
414 fi
415
416 ###############################################################################
417 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
418
419 ###     use option --disable-overwrite to leave out the link to -lcurses
420 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
421 AC_ARG_ENABLE(overwrite,
422         [  --disable-overwrite     leave out the link to -lcurses],
423         [with_overwrite=$enableval],
424         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
425 AC_MSG_RESULT($with_overwrite)
426
427 AC_MSG_CHECKING(if external terminfo-database is used)
428 AC_ARG_ENABLE(database,
429         [  --disable-database      do not use terminfo, only fallbacks/termcap],
430         [use_database=$enableval],
431         [use_database=yes])
432 AC_MSG_RESULT($use_database)
433
434 case $host_os in #(vi
435 os2*) #(vi
436         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
437         ;;
438 *) #(vi
439         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
440         ;;
441 esac
442 AC_SUBST(TERMINFO_SRC)
443
444 CF_PATHSEP
445 if test "$use_database" != no ; then
446         AC_DEFINE(USE_DATABASE)
447
448         AC_MSG_CHECKING(which terminfo source-file will be installed)
449         AC_ARG_WITH(database,
450                 [  --with-database=XXX     specify terminfo source to install],
451                 [TERMINFO_SRC=$withval])
452         AC_MSG_RESULT($TERMINFO_SRC)
453
454         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
455         AC_ARG_WITH(hashed-db,
456                 [  --with-hashed-db        specify hashed-database library],,
457                 [with_hashed_db=no])
458         AC_MSG_RESULT($with_hashed_db)
459 else
460         with_hashed_db=no
461 fi
462
463 AC_MSG_CHECKING(for list of fallback descriptions)
464 AC_ARG_WITH(fallbacks,
465         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
466         [with_fallback=$withval],
467         [with_fallback=])
468 AC_MSG_RESULT($with_fallback)
469 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
470 AC_SUBST(FALLBACK_LIST)
471
472 AC_MSG_CHECKING(if you want modern xterm or antique)
473 AC_ARG_WITH(xterm-new,
474         [  --without-xterm-new     specify if xterm terminfo should be old version],
475         [with_xterm_new=$withval],
476         [with_xterm_new=yes])
477 case $with_xterm_new in
478 no)     with_xterm_new=xterm-old;;
479 *)      with_xterm_new=xterm-new;;
480 esac
481 AC_MSG_RESULT($with_xterm_new)
482 WHICH_XTERM=$with_xterm_new
483 AC_SUBST(WHICH_XTERM)
484
485 MAKE_TERMINFO=
486 if test "$use_database" = no ; then
487         TERMINFO="${datadir}/terminfo"
488         MAKE_TERMINFO="#"
489 else
490
491 AC_MSG_CHECKING(for list of terminfo directories)
492 CF_WITH_PATHLIST(terminfo-dirs,
493         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
494         TERMINFO_DIRS,
495         DATADIR/terminfo,
496         ${datadir}/terminfo)
497 AC_MSG_RESULT($TERMINFO_DIRS)
498 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
499
500 AC_MSG_CHECKING(for default terminfo directory)
501 CF_WITH_PATH(default-terminfo-dir,
502         [  --with-default-terminfo-dir=DIR default terminfo directory],
503         TERMINFO,
504         DATADIR/terminfo,
505         ${datadir}/terminfo)
506 AC_MSG_RESULT($TERMINFO)
507 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
508
509 fi
510
511 AC_SUBST(TERMINFO)
512 AC_SUBST(MAKE_TERMINFO)
513
514 ###     use option --disable-big-core to make tic run on small machines
515 ###     We need 4Mb, check if we can allocate 50% more than that.
516 AC_MSG_CHECKING(if big-core option selected)
517 AC_ARG_ENABLE(big-core,
518         [  --disable-big-core      assume machine has little memory],
519         [with_big_core=$enableval],
520         [AC_TRY_RUN([
521 #include <stdlib.h>
522 #include <string.h>
523 int main() {
524         unsigned long n = 6000000L;
525         char *s = malloc(n);
526         if (s != 0)
527                 s[0] = s[n-1] = 0;
528         ${cf_cv_main_return:-return}(s == 0);
529 }],
530         [with_big_core=yes],
531         [with_big_core=no],
532         [with_big_core=no])])
533 AC_MSG_RESULT($with_big_core)
534 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
535
536 ### ISO C only guarantees 512-char strings, we have tables which load faster
537 ### when constructed using "big" strings.  More than the C compiler, the awk
538 ### program is a limit on most vendor UNIX systems.  Check that we can build.
539 AC_MSG_CHECKING(if big-strings option selected)
540 AC_ARG_ENABLE(big-strings,
541         [  --disable-big-strings   assume compiler has only standard-size strings],
542         [with_big_strings=$enableval],
543         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
544 AC_MSG_RESULT($with_big_strings)
545
546 USE_BIG_STRINGS=0
547 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
548 AC_SUBST(USE_BIG_STRINGS)
549
550 ###     use option --enable-termcap to compile in the termcap fallback support
551 AC_MSG_CHECKING(if you want termcap-fallback support)
552 AC_ARG_ENABLE(termcap,
553         [  --enable-termcap        compile in termcap fallback support],
554         [with_termcap=$enableval],
555         [with_termcap=no])
556 AC_MSG_RESULT($with_termcap)
557
558 if test "$with_termcap" != "yes" ; then
559         if test "$use_database" = no ; then
560                 if test -z "$with_fallback" ; then
561                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
562                 fi
563         fi
564         AC_DEFINE(PURE_TERMINFO)
565 else
566
567 if test "$with_ticlib" != no ; then
568         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
569 fi
570
571 AC_DEFINE(USE_TERMCAP)
572 AC_MSG_CHECKING(for list of termcap files)
573 CF_WITH_PATHLIST(termpath,
574         [  --with-termpath=XXX     specify list of termcap files],
575         TERMPATH,
576         /etc/termcap:/usr/share/misc/termcap)
577 AC_MSG_RESULT($TERMPATH)
578 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
579
580 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
581 AC_MSG_CHECKING(if fast termcap-loader is needed)
582 AC_ARG_ENABLE(getcap,
583         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
584         [with_getcap=$enableval],
585         [with_getcap=no])
586 AC_MSG_RESULT($with_getcap)
587 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
588
589 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
590 AC_ARG_ENABLE(getcap-cache,
591         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
592         [with_getcap_cache=$enableval],
593         [with_getcap_cache=no])
594 AC_MSG_RESULT($with_getcap_cache)
595 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
596
597 fi
598
599 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
600 AC_MSG_CHECKING(if ~/.terminfo is wanted)
601 AC_ARG_ENABLE(home-terminfo,
602         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
603         [with_home_terminfo=$enableval],
604         [with_home_terminfo=yes])
605 AC_MSG_RESULT($with_home_terminfo)
606 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
607
608 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
609 AC_ARG_ENABLE(root-environ,
610         [  --disable-root-environ  restrict environment when running as root],
611         [with_root_environ=$enableval],
612         [with_root_environ=yes])
613 AC_MSG_RESULT($with_root_environ)
614 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
615
616 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
617 ###   to reduce storage requirements for the terminfo database.
618 CF_LINK_FUNCS
619
620 with_links=no
621 with_symlinks=no
622
623 # soft links (symbolic links) are useful for some systems where hard links do
624 # not work, or to make it simpler to copy terminfo trees around.
625 if test "$ac_cv_func_symlink" = yes ; then
626     AC_MSG_CHECKING(if tic should use symbolic links)
627     AC_ARG_ENABLE(symlinks,
628         [  --enable-symlinks       make tic use symbolic links not hard links],
629         [with_symlinks=$enableval],
630         [with_symlinks=no])
631     AC_MSG_RESULT($with_symlinks)
632 fi
633
634 # If we have hard links and did not choose to use soft links instead, there is
635 # no reason to make this choice optional - use the hard links.
636 if test "$with_symlinks" = no ; then
637     AC_MSG_CHECKING(if tic should use hard links)
638     if test "$ac_cv_func_link" = yes ; then
639         with_links=yes
640     else
641         with_links=no
642     fi
643     AC_MSG_RESULT($with_links)
644 fi
645
646 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
647 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
648
649 ###   use option --enable-broken-linker to force on use of broken-linker support
650 AC_MSG_CHECKING(if you want broken-linker support code)
651 AC_ARG_ENABLE(broken_linker,
652         [  --enable-broken_linker  compile with broken-linker support code],
653         [with_broken_linker=$enableval],
654         [with_broken_linker=${BROKEN_LINKER-no}])
655 AC_MSG_RESULT($with_broken_linker)
656
657 BROKEN_LINKER=0
658 if test "$with_broken_linker" = yes ; then
659         AC_DEFINE(BROKEN_LINKER)
660         BROKEN_LINKER=1
661 elif test "$DFT_LWR_MODEL" = shared ; then
662         case $cf_cv_system_name in #(vi
663         cygwin*)
664                 AC_DEFINE(BROKEN_LINKER)
665                 BROKEN_LINKER=1
666                 CF_VERBOSE(cygwin linker is broken anyway)
667                 ;;
668         esac
669 fi
670 AC_SUBST(BROKEN_LINKER)
671
672 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
673 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
674 AC_ARG_ENABLE(bsdpad,
675         [  --enable-bsdpad         recognize BSD-style prefix padding],
676         [with_bsdpad=$enableval],
677         [with_bsdpad=no])
678 AC_MSG_RESULT($with_bsdpad)
679 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
680
681 ###   use option --enable-widec to turn on use of wide-character support
682 NCURSES_CH_T=chtype
683 NCURSES_LIBUTF8=0
684
685 NEED_WCHAR_H=0
686 NCURSES_MBSTATE_T=0
687 NCURSES_WCHAR_T=0
688 NCURSES_WINT_T=0
689
690 # Check to define _XOPEN_SOURCE "automatically"
691 CF_XOPEN_SOURCE
692
693 # Work around breakage on OS X
694 CF_SIGWINCH
695
696 # Checks for CODESET support.
697 AM_LANGINFO_CODESET
698
699 # use these variables to work around a defect in gcc's fixincludes.
700 NCURSES_OK_WCHAR_T=
701 NCURSES_OK_WINT_T=
702
703 AC_MSG_CHECKING(if you want wide-character code)
704 AC_ARG_ENABLE(widec,
705         [  --enable-widec          compile with wide-char/UTF-8 code],
706         [with_widec=$enableval],
707         [with_widec=no])
708 AC_MSG_RESULT($with_widec)
709 if test "$with_widec" = yes ; then
710         LIB_SUFFIX="w${LIB_SUFFIX}"
711         AC_DEFINE(USE_WIDEC_SUPPORT)
712         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
713         # with_overwrite=no
714         NCURSES_CH_T=cchar_t
715         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
716         if test "$ac_cv_func_putwc" != yes ; then
717                 CF_UTF8_LIB
718                 if test "$cf_cv_utf8_lib" != no ; then
719                         NCURSES_LIBUTF8=1
720                 fi
721         fi
722         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
723         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
724         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
725
726         if test "$NCURSES_MBSTATE_T" != 0; then
727                 AC_DEFINE(NEED_MBSTATE_T_DEF)
728         fi
729 fi
730 AC_SUBST(NCURSES_CH_T)
731 AC_SUBST(NCURSES_LIBUTF8)
732
733 AC_SUBST(NEED_WCHAR_H)
734 AC_SUBST(NCURSES_MBSTATE_T)
735 AC_SUBST(NCURSES_WCHAR_T)
736 AC_SUBST(NCURSES_WINT_T)
737
738 AC_SUBST(NCURSES_OK_WCHAR_T)
739 AC_SUBST(NCURSES_OK_WINT_T)
740
741 ###   use option --disable-lp64 to allow long chtype
742 case $cf_cv_abi_version in
743 [[345]]*)
744         default_with_lp64=no
745         ;;
746 *)
747         default_with_lp64=yes
748         ;;
749 esac
750
751 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
752 AC_ARG_ENABLE(lp64,
753         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
754         [with_lp64=$enableval],
755         [with_lp64=$default_with_lp64])
756 AC_MSG_RESULT($with_lp64)
757
758 if test "$with_lp64" = yes ; then
759         cf_cv_enable_lp64=1
760 else
761         cf_cv_enable_lp64=0
762 fi
763 AC_SUBST(cf_cv_enable_lp64)
764
765 CF_LARGEFILE
766
767 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
768 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
769 AC_ARG_ENABLE(tparm-varargs,
770         [  --disable-tparm-varargs compile tparm() without varargs interface],
771         [with_tparm_varargs=$enableval],
772         [with_tparm_varargs=yes])
773 AC_MSG_RESULT($with_tparm_varargs)
774 NCURSES_TPARM_VARARGS=0
775 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
776 AC_SUBST(NCURSES_TPARM_VARARGS)
777
778 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
779 if test "$with_ticlib" != no ; then
780 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
781 AC_ARG_ENABLE(tic-depends,
782         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
783         [with_tic_depends=$enableval],
784         [with_tic_depends=yes])
785 AC_MSG_RESULT($with_tic_depends)
786 else
787         with_tic_depends=no
788 fi
789
790 ###   use option --with-bool to override bool's type
791 AC_MSG_CHECKING(for type of bool)
792 AC_ARG_WITH(bool,
793         [  --with-bool=TYPE        override fallback type of bool variable],
794         [NCURSES_BOOL="$withval"],
795         [NCURSES_BOOL=auto])
796 AC_MSG_RESULT($NCURSES_BOOL)
797 AC_SUBST(NCURSES_BOOL)
798
799 AC_MSG_CHECKING(for alternate terminal capabilities file)
800 AC_ARG_WITH(caps,
801         [  --with-caps=alt         compile with alternate Caps file],
802         [TERMINFO_CAPS=Caps.$withval],
803         [TERMINFO_CAPS=Caps])
804 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
805 AC_MSG_RESULT($TERMINFO_CAPS)
806 AC_SUBST(TERMINFO_CAPS)
807
808 ###   use option --with-chtype to override chtype's type
809 AC_MSG_CHECKING(for type of chtype)
810 AC_ARG_WITH(chtype,
811         [  --with-chtype=TYPE      override type of chtype],
812         [NCURSES_CHTYPE="$withval"],
813         [NCURSES_CHTYPE=auto])
814 AC_MSG_RESULT($NCURSES_CHTYPE)
815
816 ###   use option --with-ospeed to override ospeed's type
817 AC_MSG_CHECKING(for type of ospeed)
818 AC_ARG_WITH(ospeed,
819         [  --with-ospeed=TYPE      override type of ospeed variable],
820         [NCURSES_OSPEED="$withval"],
821         [NCURSES_OSPEED=short])
822 AC_MSG_RESULT($NCURSES_OSPEED)
823 AC_SUBST(NCURSES_OSPEED)
824
825 ###   use option --with-mmask-t to override mmask_t's type
826 AC_MSG_CHECKING(for type of mmask_t)
827 AC_ARG_WITH(mmask-t,
828         [  --with-mmask-t=TYPE     override type of mmask_t],
829         [NCURSES_MMASK_T="$withval"],
830         [NCURSES_MMASK_T=auto])
831 AC_MSG_RESULT($NCURSES_MMASK_T)
832
833 ###   use option --with-ccharw-max to override CCHARW_MAX size
834 AC_MSG_CHECKING(for size CCHARW_MAX)
835 AC_ARG_WITH(ccharw-max,
836         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
837         [NCURSES_CCHARW_MAX="$withval"],
838         [NCURSES_CCHARW_MAX=5])
839 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
840 AC_SUBST(NCURSES_CCHARW_MAX)
841
842 ### Enable compiling-in rcs id's
843 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
844 AC_ARG_WITH(rcs-ids,
845         [  --with-rcs-ids          compile-in RCS identifiers],
846         [with_rcs_ids=$withval],
847         [with_rcs_ids=no])
848 AC_MSG_RESULT($with_rcs_ids)
849 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
850
851 ###############################################################################
852 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
853
854 ###############################################################################
855 CF_HELP_MESSAGE(Extensions:)
856
857 ### Note that some functions (such as const) are normally disabled anyway.
858 AC_MSG_CHECKING(if you want to build with function extensions)
859 AC_ARG_ENABLE(ext-funcs,
860         [  --disable-ext-funcs     disable function-extensions],
861         [with_ext_funcs=$enableval],
862         [with_ext_funcs=yes])
863 AC_MSG_RESULT($with_ext_funcs)
864 if test "$with_ext_funcs" = yes ; then
865         NCURSES_EXT_FUNCS=1
866         AC_DEFINE(HAVE_CURSES_VERSION)
867         AC_DEFINE(HAVE_HAS_KEY)
868         AC_DEFINE(HAVE_RESIZETERM)
869         AC_DEFINE(HAVE_RESIZE_TERM)
870         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
871         AC_DEFINE(HAVE_WRESIZE)
872         AC_DEFINE(NCURSES_EXT_FUNCS)
873         GENERATED_EXT_FUNCS=generated
874 else
875         NCURSES_EXT_FUNCS=0
876         GENERATED_EXT_FUNCS=
877 fi
878 AC_SUBST(NCURSES_EXT_FUNCS)
879 AC_SUBST(GENERATED_EXT_FUNCS)
880
881 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
882 AC_ARG_ENABLE(sp-funcs,
883         [  --enable-sp-funcs       enable experimental SCREEN-extensions],
884         [with_sp_funcs=$enableval],
885         [with_sp_funcs=no])
886 AC_MSG_RESULT($with_sp_funcs)
887 if test "$with_sp_funcs" = yes ; then
888         NCURSES_SP_FUNCS=1
889         AC_DEFINE(NCURSES_SP_FUNCS)
890         GENERATED_SP_FUNCS=generated
891 else
892         NCURSES_SP_FUNCS=0
893         GENERATED_SP_FUNCS=
894 fi
895 AC_SUBST(NCURSES_SP_FUNCS)
896 AC_SUBST(GENERATED_SP_FUNCS)
897
898 AC_MSG_CHECKING(if you want to build with experimental terminal-driver)
899 AC_ARG_ENABLE(term-driver,
900         [  --enable-term-driver    enable experimental terminal-driver],
901         [with_term_driver=$enableval],
902         [with_term_driver=no])
903 AC_MSG_RESULT($with_term_driver)
904 if test "$with_term_driver" = yes ; then
905         AC_DEFINE(USE_TERM_DRIVER)
906         if test "$with_sp_funcs" != yes ; then
907                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
908         fi
909 fi
910
911 ###   use option --enable-const to turn on use of const beyond that in XSI.
912 AC_MSG_CHECKING(for extended use of const keyword)
913 AC_ARG_ENABLE(const,
914         [  --enable-const          compile with extra/non-standard const],
915         [with_ext_const=$enableval],
916         [with_ext_const=no])
917 AC_MSG_RESULT($with_ext_const)
918 NCURSES_CONST='/*nothing*/'
919 if test "$with_ext_const" = yes ; then
920         NCURSES_CONST=const
921 fi
922 AC_SUBST(NCURSES_CONST)
923
924 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
925 AC_MSG_CHECKING(if you want to use extended colors)
926 AC_ARG_ENABLE(ext-colors,
927         [  --enable-ext-colors     compile for 256-color support],
928         [with_ext_colors=$enableval],
929         [with_ext_colors=no])
930 AC_MSG_RESULT($with_ext_colors)
931 NCURSES_EXT_COLORS=0
932 if test "$with_ext_colors" = yes ; then
933         if test "$with_widec" != yes ; then
934                 AC_MSG_ERROR(This option applies only to wide-character library)
935         else
936                 # cannot be ABI 5 since it changes sizeof(cchar_t)
937                 CF_NCURSES_ABI_6
938         fi
939         NCURSES_EXT_COLORS=1
940         AC_DEFINE(NCURSES_EXT_COLORS)
941 fi
942 AC_SUBST(NCURSES_EXT_COLORS)
943
944 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
945 AC_MSG_CHECKING(if you want to use extended mouse encoding)
946 AC_ARG_ENABLE(ext-mouse,
947         [  --enable-ext-mouse      compile for extended mouse-encoding],
948         [with_ext_mouse=$enableval],
949         [with_ext_mouse=no])
950 AC_MSG_RESULT($with_ext_mouse)
951 NCURSES_MOUSE_VERSION=1
952 if test "$with_ext_mouse" = yes ; then
953         NCURSES_MOUSE_VERSION=2
954         CF_NCURSES_ABI_6
955 fi
956 AC_SUBST(NCURSES_MOUSE_VERSION)
957
958 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
959 AC_ARG_ENABLE(no-padding,
960         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
961         [with_no_padding=$enableval],
962         [with_no_padding=$with_ext_funcs])
963 AC_MSG_RESULT($with_no_padding)
964 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
965
966 AC_CHECK_SIZEOF([signed char], 0)
967 if test "$ac_cv_sizeof_signed_char" = 1 ; then
968         NCURSES_SBOOL="signed char"
969 else
970         NCURSES_SBOOL="char"
971 fi
972 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
973 AC_ARG_ENABLE(signed-char,
974         [  --enable-signed-char    compile using signed Boolean's in term.h],
975         [with_signed_char=$enableval],
976         [with_signed_char=no])
977 AC_MSG_RESULT($with_signed_char)
978 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
979 AC_SUBST(NCURSES_SBOOL)
980
981 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
982 AC_MSG_CHECKING(if you want SIGWINCH handler)
983 AC_ARG_ENABLE(sigwinch,
984         [  --enable-sigwinch       compile with SIGWINCH handler],
985         [with_sigwinch=$enableval],
986         [with_sigwinch=$with_ext_funcs])
987 AC_MSG_RESULT($with_sigwinch)
988 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
989
990 ###   use option --enable-tcap-names to allow user to define new capabilities
991 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
992 AC_ARG_ENABLE(tcap-names,
993         [  --enable-tcap-names     compile with user-definable terminal capabilities],
994         [with_tcap_names=$enableval],
995         [with_tcap_names=$with_ext_funcs])
996 AC_MSG_RESULT($with_tcap_names)
997 NCURSES_XNAMES=0
998 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
999 AC_SUBST(NCURSES_XNAMES)
1000
1001 ###############################################################################
1002 # These options are relatively safe to experiment with.
1003 CF_HELP_MESSAGE(Development Code:)
1004 AC_MSG_CHECKING(if you want all development code)
1005 AC_ARG_WITH(develop,
1006         [  --without-develop       disable development options],
1007         [with_develop=$withval],
1008         [with_develop=no])
1009 AC_MSG_RESULT($with_develop)
1010
1011 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1012 AC_MSG_CHECKING(if you want hard-tabs code)
1013 AC_ARG_ENABLE(hard-tabs,
1014         [  --enable-hard-tabs      compile with hard-tabs code],,
1015         [enable_hard_tabs=$with_develop])
1016 AC_MSG_RESULT($enable_hard_tabs)
1017 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
1018
1019 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1020 AC_MSG_CHECKING(if you want limited support for xmc)
1021 AC_ARG_ENABLE(xmc-glitch,
1022         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1023         [enable_xmc_glitch=$with_develop])
1024 AC_MSG_RESULT($enable_xmc_glitch)
1025 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
1026
1027 ###############################################################################
1028 # These are just experimental, probably should not be in a package:
1029 CF_HELP_MESSAGE(Experimental Code:)
1030
1031 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1032 AC_ARG_ENABLE(assumed-color,
1033         [  --disable-assumed-color do not assume anything about default-colors],
1034         [with_assumed_color=$enableval],
1035         [with_assumed_color=yes])
1036 AC_MSG_RESULT($with_assumed_color)
1037 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
1038
1039 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1040 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1041 AC_ARG_ENABLE(hashmap,
1042         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1043         [with_hashmap=$enableval],
1044         [with_hashmap=yes])
1045 AC_MSG_RESULT($with_hashmap)
1046 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
1047
1048 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1049 AC_MSG_CHECKING(if you want colorfgbg code)
1050 AC_ARG_ENABLE(colorfgbg,
1051         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1052         [with_colorfgbg=$enableval],
1053         [with_colorfgbg=no])
1054 AC_MSG_RESULT($with_colorfgbg)
1055 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
1056
1057 ###   use option --enable-interop to turn on use of bindings used for interop
1058 AC_MSG_CHECKING(if you want interop bindings)
1059 AC_ARG_ENABLE(interop,
1060         [  --enable-interop        compile-in experimental interop bindings],
1061         [with_exp_interop=$enableval],
1062         [with_exp_interop=no])
1063 AC_MSG_RESULT($with_exp_interop)
1064
1065 NCURSES_INTEROP_FUNCS=0
1066 test "$with_exp_interop" = yes && NCURSES_INTEROP_FUNCS=1
1067 AC_SUBST(NCURSES_INTEROP_FUNCS)
1068
1069 # This is still experimental (20080329), but should ultimately be moved to
1070 # the script-block --with-normal, etc.
1071 CF_WITH_PTHREAD
1072
1073 AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1074 AC_ARG_ENABLE(weak-symbols,
1075     [  --enable-weak-symbols   enable weak-symbols for pthreads],
1076     [use_weak_symbols=$withval],
1077     [use_weak_symbols=no])
1078 AC_MSG_RESULT($use_weak_symbols)
1079 if test "$use_weak_symbols" = yes ; then
1080     CF_WEAK_SYMBOLS
1081 else
1082     cf_cv_weak_symbols=no
1083 fi
1084
1085 if test $cf_cv_weak_symbols = yes ; then
1086     AC_DEFINE(USE_WEAK_SYMBOLS)
1087 fi
1088
1089 PTHREAD=
1090 if test "$with_pthread" = "yes" ; then
1091     AC_DEFINE(USE_PTHREADS)
1092     enable_reentrant=yes
1093     if test $cf_cv_weak_symbols = yes ; then
1094         PTHREAD=-lpthread
1095     fi
1096 fi
1097 AC_SUBST(PTHREAD)
1098
1099 # Reentrant code has to be opaque; there's little advantage to making ncurses
1100 # opaque outside of that, so there is no --enable-opaque option.  We can use
1101 # this option without --with-pthreads, but this will be always set for
1102 # pthreads.
1103 AC_MSG_CHECKING(if you want experimental reentrant code)
1104 AC_ARG_ENABLE(reentrant,
1105         [  --enable-reentrant      compile with experimental reentrant code],
1106         [with_reentrant=$enableval],
1107         [with_reentrant=no])
1108 AC_MSG_RESULT($with_reentrant)
1109 if test "$with_reentrant" = yes ; then
1110         cf_cv_enable_reentrant=1
1111         cf_cv_enable_opaque="NCURSES_INTERNALS"
1112         NCURSES_OPAQUE=1
1113         NCURSES_SIZE_T=int
1114         if test $cf_cv_weak_symbols = yes ; then
1115                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1116         else
1117                 LIB_SUFFIX="t${LIB_SUFFIX}"
1118         fi
1119         AC_DEFINE(USE_REENTRANT)
1120         CF_NCURSES_ABI_6
1121 else
1122         cf_cv_enable_reentrant=0
1123         cf_cv_enable_opaque="NCURSES_OPAQUE"
1124         NCURSES_OPAQUE=0
1125         NCURSES_SIZE_T=short
1126 fi
1127 AC_SUBST(cf_cv_enable_reentrant)
1128 AC_SUBST(cf_cv_enable_opaque)
1129 AC_SUBST(NCURSES_OPAQUE)
1130 AC_SUBST(NCURSES_SIZE_T)
1131
1132 ### Allow using a different wrap-prefix
1133 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1134         AC_MSG_CHECKING(for prefix used to wrap public variables)
1135         AC_ARG_WITH(wrap-prefix,
1136                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1137                 [NCURSES_WRAP_PREFIX=$withval],
1138                 [NCURSES_WRAP_PREFIX=_nc_])
1139         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1140 else
1141         NCURSES_WRAP_PREFIX=_nc_
1142 fi
1143 AC_SUBST(NCURSES_WRAP_PREFIX)
1144 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX")
1145
1146 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1147 AC_ARG_ENABLE(safe-sprintf,
1148         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1149         [with_safe_sprintf=$enableval],
1150         [with_safe_sprintf=no])
1151 AC_MSG_RESULT($with_safe_sprintf)
1152 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1153
1154 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1155 # when hashmap is used scroll hints are useless
1156 if test "$with_hashmap" = no ; then
1157 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1158 AC_ARG_ENABLE(scroll-hints,
1159         [  --disable-scroll-hints  compile without scroll-hints code],
1160         [with_scroll_hints=$enableval],
1161         [with_scroll_hints=yes])
1162 AC_MSG_RESULT($with_scroll_hints)
1163 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1164 fi
1165
1166 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1167 AC_ARG_ENABLE(wgetch-events,
1168         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1169         [with_wgetch_events=$enableval],
1170         [with_wgetch_events=no])
1171 AC_MSG_RESULT($with_wgetch_events)
1172 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1173
1174 ###############################################################################
1175 CF_HELP_MESSAGE(Testing/development Options:)
1176
1177 ###     use option --disable-echo to suppress full display compiling commands
1178 AC_MSG_CHECKING(if you want to display full commands during build)
1179 AC_ARG_ENABLE(echo,
1180         [  --enable-echo           build: display "compiling" commands (default)],
1181         [with_echo=$enableval],
1182         [with_echo=yes])
1183 if test "$with_echo" = yes; then
1184         ECHO_LINK=
1185 else
1186         ECHO_LINK='@ echo linking $@ ... ;'
1187         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1188         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1189 fi
1190 AC_MSG_RESULT($with_echo)
1191 AC_SUBST(ECHO_LINK)
1192
1193 ###     use option --enable-warnings to turn on all gcc warnings
1194 AC_MSG_CHECKING(if you want to see compiler warnings)
1195 AC_ARG_ENABLE(warnings,
1196         [  --enable-warnings       build: turn on GCC compiler warnings],
1197         [with_warnings=$enableval])
1198 AC_MSG_RESULT($with_warnings)
1199
1200 if test "x$with_warnings" = "xyes"; then
1201         ADAFLAGS="$ADAFLAGS -gnatg"
1202         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1203         if test "$cf_with_cxx" = yes ; then
1204                 CF_GXX_WARNINGS(Wno-unused)
1205         fi
1206 fi
1207 CF_GCC_ATTRIBUTES
1208
1209 ###     use option --enable-assertions to turn on generation of assertion code
1210 AC_MSG_CHECKING(if you want to enable runtime assertions)
1211 AC_ARG_ENABLE(assertions,
1212         [  --enable-assertions     test: turn on generation of assertion code],
1213         [with_assertions=$enableval],
1214         [with_assertions=no])
1215 AC_MSG_RESULT($with_assertions)
1216 if test -n "$GCC"
1217 then
1218         if test "$with_assertions" = no
1219         then
1220                 AC_DEFINE(NDEBUG)
1221                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1222         else
1223                 ADAFLAGS="$ADAFLAGS -gnata"
1224         fi
1225 fi
1226
1227 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1228 CF_DISABLE_LEAKS
1229 AC_DEFINE(HAVE_NC_ALLOC_H)
1230
1231 ###     use option --enable-expanded to generate certain macros as functions
1232 AC_ARG_ENABLE(expanded,
1233         [  --enable-expanded       test: generate functions for certain macros],
1234         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1235
1236 ###     use option --disable-macros to suppress macros in favor of functions
1237 AC_ARG_ENABLE(macros,
1238         [  --disable-macros        test: use functions rather than macros],
1239         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1240
1241 # Normally we only add trace() to the debug-library.  Allow this to be
1242 # extended to all models of the ncurses library:
1243 cf_all_traces=no
1244 case "$CFLAGS $CPPFLAGS" in
1245 *-DTRACE*)
1246         cf_all_traces=yes
1247         ;;
1248 esac
1249
1250 AC_MSG_CHECKING(whether to add trace feature to all models)
1251 AC_ARG_WITH(trace,
1252 [  --with-trace            test: add trace() function to all models of ncurses],
1253 [cf_with_trace=$withval],
1254 [cf_with_trace=$cf_all_traces])
1255 AC_MSG_RESULT($cf_with_trace)
1256
1257 if test "$cf_with_trace" = yes ; then
1258         LIB_TRACING=all
1259         ADA_TRACE=TRUE
1260         CF_ADD_CFLAGS(-DTRACE)
1261 else
1262         LIB_TRACING=DEBUG
1263         ADA_TRACE=FALSE
1264 fi
1265
1266 AC_SUBST(ADA_TRACE)
1267
1268 ###     Checks for libraries.
1269 case $cf_cv_system_name in #(vi
1270 *mingw32*) #(vi
1271         ;;
1272 *)
1273 AC_CHECK_FUNC(gettimeofday,
1274         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1275
1276 AC_CHECK_LIB(bsd, gettimeofday,
1277         AC_DEFINE(HAVE_GETTIMEOFDAY)
1278         LIBS="$LIBS -lbsd")])dnl CLIX: bzero, select, gettimeofday
1279         ;;
1280 esac
1281
1282 CF_MATH_LIB(MATH_LIB,sin(x))
1283 AC_SUBST(MATH_LIB)
1284
1285 ###     Checks for header files.
1286 AC_STDC_HEADERS
1287 AC_HEADER_DIRENT
1288 AC_HEADER_TIME
1289 CF_REGEX
1290
1291 dnl These are some other potentially nonportable headers.
1292 AC_CHECK_HEADERS( \
1293 fcntl.h \
1294 getopt.h \
1295 limits.h \
1296 locale.h \
1297 poll.h \
1298 sys/bsdtypes.h \
1299 sys/ioctl.h \
1300 sys/param.h \
1301 sys/poll.h \
1302 sys/select.h \
1303 sys/time.h \
1304 sys/times.h \
1305 ttyent.h \
1306 unistd.h \
1307 wctype.h \
1308 )
1309
1310 # check for ISC (this may also define _POSIX_SOURCE)
1311 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1312 if test "$ISC" = yes ; then
1313         AC_CHECK_LIB(cposix,main)
1314         AC_CHECK_LIB(inet,bzero,LIBS="$LIBS -linet")dnl also 'select()'
1315 fi
1316
1317 CF_SYS_TIME_SELECT
1318
1319 ###     checks for compiler characteristics
1320 AC_LANG_C
1321 AC_C_CONST
1322 CF_C_INLINE(NCURSES_INLINE,1200)
1323 CF_SIG_ATOMIC_T
1324
1325 if test $NCURSES_CHTYPE = auto ; then
1326         CF_TYPEOF_CHTYPE
1327 else
1328         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1329 fi
1330 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1331 AC_SUBST(cf_cv_typeof_chtype)
1332
1333 CF_UNSIGNED_LITERALS
1334 cf_cv_1UL="1"
1335 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1336 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1337 AC_SUBST(cf_cv_1UL)
1338
1339 if test $NCURSES_MMASK_T = auto ; then
1340         cf_cv_typeof_mmask_t=long
1341 else
1342         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1343 fi
1344 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1345 AC_SUBST(cf_cv_typeof_mmask_t)
1346
1347 ###     Checks for external-data
1348 CF_ERRNO
1349 CF_LINK_DATAONLY
1350
1351 ###     Checks for library functions.
1352 AC_CHECK_FUNCS( \
1353 getcwd \
1354 getegid \
1355 geteuid \
1356 getttynam \
1357 issetugid \
1358 poll \
1359 remove \
1360 select \
1361 setbuf \
1362 setbuffer \
1363 setvbuf \
1364 sigaction \
1365 sigvec \
1366 strdup \
1367 strstr \
1368 tcgetpgrp \
1369 times \
1370 vsnprintf \
1371 )
1372 if test "$with_getcap" = "yes" ; then
1373         CF_CGETENT
1374 fi
1375
1376 CF_ISASCII
1377 CF_STRUCT_SIGACTION
1378 CF_FUNC_NANOSLEEP
1379 CF_FUNC_TERMIOS
1380 CF_FUNC_VSSCANF
1381 CF_MKSTEMP
1382
1383 # setup for prototype of fallback for vsscanf()
1384 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1385
1386 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1387 if test "$cross_compiling" = yes ; then
1388         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1389 else
1390         AC_FUNC_SETVBUF_REVERSED
1391 fi
1392 AC_TYPE_SIGNAL
1393 CF_TYPE_SIGACTION
1394 CF_SIZECHANGE
1395 CF_FUNC_MEMMOVE
1396 CF_FUNC_POLL
1397 CF_VA_COPY
1398 AC_FUNC_VFORK
1399
1400 # special check for test/ditto.c
1401 CF_FUNC_OPENPTY
1402 if test "$cf_cv_func_openpty" != no ; then
1403     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1404     AC_DEFINE(USE_XTERM_PTY)
1405     if test "$cf_cv_lib_util" = yes ; then
1406         TEST_LIBS="-lutil $TEST_LIBS"
1407     fi
1408 fi
1409 AC_SUBST(TEST_LIBS)
1410
1411 if test "$with_hashed_db" != no ; then
1412         AC_DEFINE(USE_HASHED_DB)
1413         CF_HASHED_DB($with_hashed_db)
1414 fi
1415
1416 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1417 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1418         CF_STRIP_G_OPT(CFLAGS)
1419         CF_STRIP_G_OPT(CXXFLAGS)
1420 fi
1421
1422 # Just in case, check if the C compiler has a bool type.
1423 CF_BOOL_DECL(cf_cv_cc_bool_type)
1424
1425 # Check for C++ compiler characteristics (and ensure that it's there!)
1426 if test -n "$CXX" ; then
1427         AC_LANG_CPLUSPLUS
1428         CF_STDCPP_LIBRARY
1429         CF_PROG_CC_C_O(CXX)
1430
1431         case $GXX_VERSION in
1432         1*|2.[0-6]*)
1433                 cf_cxx_library=yes
1434                 ;;
1435         *-2.7*|2.7*)
1436                 CF_GPP_LIBRARY
1437                 ;;
1438         *)
1439                 cf_cxx_library=no
1440                 ;;
1441         esac
1442
1443         AC_CHECK_HEADERS(iostream typeinfo)
1444
1445     if test x"$ac_cv_header_iostream" = xyes ; then
1446         AC_MSG_CHECKING(if iostream uses std-namespace)
1447         AC_TRY_COMPILE([
1448 #include <iostream>
1449 using std::endl;
1450 using std::cerr;],[
1451 cerr << "testing" << endl;
1452 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1453         AC_MSG_RESULT($cf_iostream_namespace)
1454         if test "$cf_iostream_namespace" = yes ; then
1455             AC_DEFINE(IOSTREAM_NAMESPACE)
1456         fi
1457     fi
1458
1459         CF_BOOL_DECL
1460         CF_BOOL_SIZE
1461         CF_ETIP_DEFINES
1462         CF_CPP_PARAM_INIT
1463         CF_CPP_STATIC_CAST
1464
1465         CXX_AR='$(AR)'
1466         CXX_ARFLAGS='$(ARFLAGS)'
1467         case $cf_cv_system_name in #(vi
1468         irix*) #(vi
1469             if test "$GXX" != yes ; then
1470                 CXX_AR='$(CXX)'
1471                 CXX_ARFLAGS='-ar -o'
1472             fi
1473             ;;
1474         sco3.2v5*) #(vi
1475             CXXLDFLAGS="-u main"
1476             ;;
1477         solaris2*)
1478             if test "$GXX" != yes ; then
1479                 CXX_AR='$(CXX)'
1480                 CXX_ARFLAGS='-xar -o'
1481             fi
1482             ;;
1483         esac
1484         AC_SUBST(CXXLDFLAGS)
1485         AC_SUBST(CXX_AR)
1486         AC_SUBST(CXX_ARFLAGS)
1487 else
1488         cf_cxx_library=no
1489         cf_cv_builtin_bool=1
1490
1491         # Just because we are not configuring against C++ right now does not
1492         # mean that a user will not want to use C++.  Some distributors disable
1493         # the C++ portion of this configuration as a shortcut (or just to avoid
1494         # compiling the demo in the c++ directory).  So we need a reasonable
1495         # default for the 'bool' type.
1496         #
1497         # Caveat: since the storage of the bool type is not standardized, it
1498         # may change.
1499
1500         if test "$NCURSES_BOOL" != auto ; then
1501                 cf_cv_type_of_bool=$NCURSES_BOOL
1502                 cf_cv_header_stdbool_h=0
1503         else
1504                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1505                         CF_BOOL_SIZE
1506                 else
1507                         AC_MSG_CHECKING(for fallback type of bool)
1508                         case "$host_cpu" in #(vi
1509                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1510                         *)      cf_cv_type_of_bool=int  ;;
1511                         esac
1512                         AC_MSG_RESULT($cf_cv_type_of_bool)
1513                 fi
1514         fi
1515 fi
1516 AC_SUBST(CXXLIBS)
1517
1518 # If the C compiler did not declare bool, and we did not determine that the C++
1519 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1520 # ncurses library use the same type as C++ bool.  Note that this allows one to
1521 # specify the type of bool in a configure-script option and postpone
1522 # integration with the C++ compiler provided that the types are compatible.
1523 USE_CXX_BOOL=1
1524 if test $cf_cv_cc_bool_type = 1
1525 then
1526         # oops: C has a bool.  Unlikely, but C++ could differ.
1527         USE_CXX_BOOL=0
1528 elif test $cf_cv_builtin_bool = 0
1529 then
1530         # C++ has no bool
1531         USE_CXX_BOOL=0
1532 else
1533         # this is the normal case
1534         USE_CXX_BOOL='defined(__cplusplus)'
1535 fi
1536 AC_SUBST(USE_CXX_BOOL)
1537
1538 CF_HELP_MESSAGE(Ada95 Binding Options:)
1539
1540 dnl If the Ada95 source-tree is present, add that to the build unless it will
1541 dnl not work, or was not requested.
1542 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1543
1544 dnl libtool does not know anything about GNAT, though a change made in 1998
1545 dnl provided for it "someday".  Disable the ada subtree if we are using
1546 dnl libtool -TD 20070714
1547 if test "$cf_with_ada" != "no" ; then
1548     if test "$with_libtool" != "no"; then
1549         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1550         cf_with_ada=no
1551     fi
1552 fi
1553
1554 dnl Check for availability of GNU Ada Translator (GNAT).
1555 dnl At the moment we support no other Ada95 compiler.
1556 if test "$cf_with_ada" != "no" ; then
1557 cf_ada_make=gnatmake
1558 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
1559 if test "$ac_cv_prog_gnat_exists" = no; then
1560    cf_ada_make=
1561 else
1562    CF_GNAT_VERSION
1563    AC_CHECK_PROG(M4_exists, m4, yes, no)
1564    if test "$ac_cv_prog_M4_exists" = no; then
1565       cf_cv_prog_gnat_correct=no
1566       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
1567    fi
1568    if test "$cf_cv_prog_gnat_correct" = yes; then
1569       AC_MSG_CHECKING(if GNAT works)
1570       CF_GNAT_TRY_RUN([procedure conftest;],
1571 [with Text_IO;
1572 with GNAT.OS_Lib;
1573 procedure conftest is
1574 begin
1575    Text_IO.Put ("Hello World");
1576    Text_IO.New_Line;
1577    GNAT.OS_Lib.OS_Exit (0);
1578 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
1579       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
1580    fi
1581 fi
1582 if test "$cf_cv_prog_gnat_correct" = yes; then
1583    ADAFLAGS="-O3 -gnatpn $ADAFLAGS"
1584
1585    AC_MSG_CHECKING(if GNAT pragma Unreferenced works)
1586    CF_GNAT_TRY_LINK([procedure conftest;],
1587 [with Text_IO;
1588 with GNAT.OS_Lib;
1589 procedure conftest is
1590    test : Integer;
1591    pragma Unreferenced (test);
1592 begin
1593    test := 1;
1594    Text_IO.Put ("Hello World");
1595    Text_IO.New_Line;
1596    GNAT.OS_Lib.OS_Exit (0);
1597 end conftest;],[cf_cv_pragma_unreferenced=yes],[cf_cv_pragma_unreferenced=no])
1598    AC_MSG_RESULT($cf_cv_pragma_unreferenced)
1599
1600    # if the pragma is supported, use it (needed in the Trace code).
1601    if test $cf_cv_pragma_unreferenced = yes ; then
1602       PRAGMA_UNREF=TRUE
1603    else
1604       PRAGMA_UNREF=FALSE
1605    fi
1606
1607    AC_ARG_WITH(ada-compiler,
1608         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
1609         [cf_ada_compiler=$withval],
1610         [cf_ada_compiler=gnatmake])
1611
1612    cf_ada_package=terminal_interface
1613
1614    AC_SUBST(cf_ada_make)
1615    AC_SUBST(cf_ada_compiler)
1616    AC_SUBST(cf_ada_package)
1617    AC_SUBST(ADAFLAGS)
1618    AC_SUBST(cf_compile_generics)
1619    AC_SUBST(cf_generic_objects)
1620    AC_SUBST(PRAGMA_UNREF)
1621
1622    CF_WITH_PATH(ada-include,
1623        [  --with-ada-include=DIR  Ada includes are in DIR],
1624        ADA_INCLUDE,
1625        PREFIX/lib/ada/adainclude,
1626        [$]prefix/lib/ada/adainclude)
1627    AC_SUBST(ADA_INCLUDE)
1628
1629    CF_WITH_PATH(ada-objects,
1630        [  --with-ada-objects=DIR  Ada objects are in DIR],
1631        ADA_OBJECTS,
1632        PREFIX/lib/ada/adalib,
1633        [$]prefix/lib/ada/adalib)
1634    AC_SUBST(ADA_OBJECTS)
1635
1636 fi
1637 fi
1638 else
1639    cf_with_ada=no
1640 fi
1641
1642 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1643 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1644 ###
1645 ### ticlib modules may be a separate library, otherwise contained in termlib.
1646 ### termlib modules may be a separate library, otherwise contained in ncurses.
1647 ###
1648 ### The of "+" or " " between the tokens controls the way the script
1649 ### chooses to split module lists into libraries.
1650 ###
1651 ### (see CF_LIB_RULES).
1652 AC_MSG_CHECKING(for library subsets)
1653 LIB_SUBSETS=
1654
1655 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1656         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1657         if test "$with_ticlib" != no ; then
1658                 LIB_SUBSETS="${LIB_SUBSETS} "
1659         else
1660                 LIB_SUBSETS="${LIB_SUBSETS}+"
1661         fi
1662 fi
1663
1664 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1665 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1666
1667 if test "$with_termlib" != no ; then
1668         LIB_SUBSETS="${LIB_SUBSETS} "
1669 else
1670         LIB_SUBSETS="${LIB_SUBSETS}+"
1671 fi
1672
1673 LIB_SUBSETS="${LIB_SUBSETS}base"
1674
1675 # Most term-driver calls are to tinfo, but some like init_pair are to the
1676 # base library (so it resides in base).
1677 if test "$with_term_driver" != no ; then
1678         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1679         case $cf_cv_system_name in #(vi
1680         *mingw32*) #(vi
1681                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1682                 ;;
1683         *) #(vi
1684                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1685                 ;;
1686         esac
1687 fi
1688
1689 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1690 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1691
1692 AC_MSG_RESULT($LIB_SUBSETS)
1693
1694 ### Construct the list of include-directories to be generated
1695 CF_INCLUDE_DIRS
1696 CF_ADA_INCLUDE_DIRS
1697
1698 ### Build up pieces for makefile rules
1699 AC_MSG_CHECKING(default library suffix)
1700 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1701 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1702 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1703
1704 AC_MSG_CHECKING(default library-dependency suffix)
1705 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1706 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1707 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1708
1709 AC_MSG_CHECKING(default object directory)
1710 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1711 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1712 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1713
1714 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1715 if test "$cf_with_cxx" = yes ; then
1716 AC_MSG_CHECKING(c++ library-dependency suffix)
1717 if test "$with_libtool" != "no"; then
1718         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1719 else
1720         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)dnl we normally make a static library
1721 fi
1722 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1723 AC_SUBST(CXX_LIB_SUFFIX)
1724 fi
1725
1726 # do not want -ldl in build except as needed for -lncurses dependency
1727 if test "$with_dlsym" = yes ; then
1728 if test $DFT_LWR_MODEL = shared || \
1729    test $DFT_LWR_MODEL = libtool ; then
1730         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1731 fi
1732 fi
1733 ### Set up low-level terminfo dependencies for makefiles.
1734
1735 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1736 # do not need libdl
1737 TICS_LIST=
1738 if test "$with_dlsym" = yes ; then
1739         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1740 fi
1741
1742 if test "$with_ticlib" != no ; then
1743
1744         if test "$with_ticlib" != yes ; then
1745                 TICS_NAME=$with_ticlib
1746                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1747                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1748                 TICS_LIB_SUFFIX="${with_ticlib}"
1749         else
1750                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1751                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1752                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1753         fi
1754         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1755 else
1756         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1757 fi
1758 AC_SUBST(TICS_ARG_SUFFIX)
1759 AC_SUBST(TICS_DEP_SUFFIX)
1760 AC_SUBST(TICS_LIB_SUFFIX)
1761 AC_SUBST(TICS_ARGS)
1762
1763 if test "$with_termlib" != no ; then
1764
1765         if test "$with_termlib" != yes ; then
1766                 TINFO_NAME=$with_termlib
1767                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1768                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1769                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1770                 TINFO_LIB_SUFFIX="${with_termlib}"
1771         else
1772                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1773                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1774                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1775                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1776         fi
1777
1778         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1779         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1780         if test "$DFT_LWR_MODEL" = "libtool"; then
1781                 TEST_ARGS="${TEST_DEPS}"
1782                 TEST_ARG2="${TEST_DEP2}"
1783                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1784                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1785                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1786         else
1787                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1788                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1789                 TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1790                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1791                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1792         fi
1793 else
1794         # the next lines are needed for linking libtic over libncurses
1795         TINFO_NAME=${LIB_NAME}
1796         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1797         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1798         if test "$with_tic_depends" = yes ; then
1799                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1800         else
1801                 TICS_LIST="$SHLIB_LIST"
1802         fi
1803
1804         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1805 fi
1806
1807 if test "$DFT_LWR_MODEL" = shared ; then
1808         case $cf_cv_system_name in #(vi
1809         cygwin*)
1810                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1811                 TINFO_SUFFIX=.dll
1812                 ;;
1813         esac
1814 fi
1815
1816 AC_SUBST(TINFO_ARG_SUFFIX)
1817 AC_SUBST(TINFO_DEP_SUFFIX)
1818 AC_SUBST(TINFO_LIB_SUFFIX)
1819 AC_SUBST(TINFO_ARGS)
1820
1821 if test "$with_dlsym" = yes ; then
1822         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1823 fi
1824
1825 if test "$DFT_LWR_MODEL" = "libtool"; then
1826     OBJEXT=lo
1827 fi
1828
1829 # needed for Ada95
1830 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1831 AC_SUBST(TINFO_ARGS2)
1832
1833 case $DFT_LWR_MODEL in
1834 normal|debug|profile)
1835         CF_LDFLAGS_STATIC
1836         ;;
1837 esac
1838
1839 AC_MSG_CHECKING(where we will install curses.h)
1840 test "$with_overwrite" = no && \
1841 test "x$includedir" = 'x${prefix}/include' && \
1842         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1843 AC_MSG_RESULT($includedir)
1844
1845 ### Resolve a conflict between normal and wide-curses by forcing applications
1846 ### that will need libutf8 to add it to their configure script.
1847 if test "$with_overwrite" != no ; then
1848 if test "$NCURSES_LIBUTF8" = 1 ; then
1849         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1850         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1851 fi
1852 fi
1853 WITH_OVERWRITE=$with_overwrite
1854
1855 AC_SUBST(WITH_OVERWRITE)
1856 AC_SUBST(TICS_LIST)
1857 AC_SUBST(TINFO_LIST)
1858 AC_SUBST(SHLIB_LIST)
1859
1860 # used to separate tack out of the tree
1861 NCURSES_TREE=
1862 AC_SUBST(NCURSES_TREE)
1863
1864 ### predefined stuff for the test programs
1865 AC_DEFINE(HAVE_SLK_COLOR)
1866
1867 ### Construct the list of subdirectories for which we'll customize makefiles
1868 ### with the appropriate compile-rules.
1869
1870 CF_SRC_MODULES($modules_to_build)
1871
1872 if test "$cf_with_ada" != "no" && test "$cf_cv_prog_gnat_correct" != "no"; then
1873    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1874    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${DFT_ARG_SUFFIX}-config.1:man/MKada_config.in"
1875 fi
1876
1877 CF_DIRS_TO_MAKE
1878
1879 # symbols that differ when compiling Ada95 by itself.
1880 NCURSES_SHLIB2='sh $(top_srcdir)/misc/shlib'
1881 AC_SUBST(NCURSES_SHLIB2)
1882
1883 NCURSES_COPY2='sh $(top_srcdir)/tar-copy.sh'
1884 AC_SUBST(NCURSES_COPY2)
1885
1886 # values to use as strings
1887 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR')
1888
1889 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1890
1891 ### Now that we're done running tests, add the compiler-warnings, if any
1892 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1893
1894 ### If we're building with rpath, try to link non-standard libs that way too.
1895 if test "$DFT_LWR_MODEL" = "shared"; then
1896   CF_RPATH_HACK
1897 fi
1898
1899 ### Define substitutions for header files to avoid name-pollution
1900 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1901 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1902 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1903
1904 ################################################################################
1905 test "$use_database" = yes && \
1906 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1907
1908 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1909 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${DFT_ARG_SUFFIX}${cf_cv_abi_version}-config.1:man/MKncu_config.in"
1910
1911 if test x"$enable_pc_files" = xyes ; then \
1912 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1913 MAKE_PC_FILES=
1914 else
1915 MAKE_PC_FILES="#"
1916 fi
1917 AC_SUBST(MAKE_PC_FILES)
1918 AC_SUBST(cross_compiling)
1919
1920 AC_OUTPUT( \
1921         include/MKterm.h.awk \
1922         include/curses.head:include/curses.h.in \
1923         include/ncurses_dll.h \
1924         include/termcap.h \
1925         include/unctrl.h \
1926         $SUB_MAKEFILES \
1927         Makefile,[
1928 CF_PRG_RULES([$srcdir/test/mk-test.awk ECHO_LINK="$ECHO_LINK"], test)
1929 CF_LIB_RULES($SRC_SUBDIRS)
1930 ],[
1931 ### Special initialization commands, used to pass information from the
1932 ### configuration-run into config.status
1933
1934 AWK="$AWK"
1935 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1936 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1937 ECHO_LINK="$ECHO_LINK"
1938 LDCONFIG="$LDCONFIG"
1939 LIB_NAME="$LIB_NAME"
1940 LIB_SUBSETS="$LIB_SUBSETS"
1941 LIB_SUFFIX="$LIB_SUFFIX"
1942 LIB_TRACING="$LIB_TRACING"
1943 MAKE_TERMINFO="$MAKE_TERMINFO"
1944 NCURSES_MAJOR="$NCURSES_MAJOR"
1945 NCURSES_MINOR="$NCURSES_MINOR"
1946 NCURSES_OSPEED="$NCURSES_OSPEED"
1947 NCURSES_PATCH="$NCURSES_PATCH"
1948 SRC_SUBDIRS="$SRC_SUBDIRS"
1949 TERMINFO="$TERMINFO"
1950 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1951 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1952 TICS_NAME="$TICS_NAME"
1953 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1954 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1955 TINFO_NAME="$TINFO_NAME"
1956 TINFO_SUFFIX="$TINFO_SUFFIX"
1957 WITH_CURSES_H="$with_curses_h"
1958 WITH_ECHO="$with_echo"
1959 WITH_OVERWRITE="$with_overwrite"
1960 cf_LIST_MODELS="$cf_list_models"
1961 cf_cv_abi_version="$cf_cv_abi_version"
1962 cf_cv_do_relink="$cf_cv_do_relink"
1963 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1964 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1965 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1966 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1967 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1968 cf_cv_rel_version="$cf_cv_rel_version"
1969 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1970 cf_cv_shared_soname='$cf_cv_shared_soname'
1971 cf_cv_shlib_version="$cf_cv_shlib_version"
1972 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1973 cf_cv_system_name="$cf_cv_system_name"
1974 cf_with_cxx_binding="$cf_with_cxx_binding"
1975 cf_with_manpages="$cf_with_manpages"
1976 host="$host"
1977 target="$target"
1978
1979 ],cat)dnl
1980 ${MAKE-make} preinstall