configure.in

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2021,2022 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: configure.in,v 1.747 2022/08/20 19:54:19 tom Exp $
  33 dnl Process this file with autoconf to produce a configure script.
  34 dnl
  35 dnl For additional information, see
  36 dnl     https://invisible-island.net/autoconf/
  37 dnl     https://invisible-island.net/autoconf/my-autoconf.html
  38 dnl
  39 dnl ---------------------------------------------------------------------------
  40 AC_PREREQ(2.52.20210101)
  41 AC_REVISION($Revision: 1.747 $)
  42 AC_INIT(ncurses/base/lib_initscr.c)
  43 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  44
  45 AC_DEFUN([AC_PATH_XTRA],[])dnl ignore dependencies on this
  46
  47 CF_TOP_BUILDDIR
  48 CF_SUBST_NCURSES_VERSION
  49 CF_VERSION_INFO(NCURSES,ncurses)
  50
  51 CF_WITH_REL_VERSION(NCURSES)
  52 CF_NCURSES_WITH_ABI_VERSION
  53
  54 CF_WITH_SYSTYPE
  55
  56 ###     Save the given $CFLAGS to allow user-override.
  57 cf_user_CFLAGS="$CFLAGS"
  58
  59 ###     Default install-location
  60 CF_CFG_DEFAULTS
  61 ### Defaults for ncurses ABI
  62 CF_ABI_DEFAULTS
  63
  64 ###     Checks for programs.
  65 AC_ARG_WITH(ada,
  66         [  --without-ada           suppress check for Ada compiler, don't build demo],
  67         [cf_with_ada=$withval],
  68         [cf_with_ada=yes])
  69
  70 if test "x$cf_with_ada" = xyes
  71 then
  72         cf_prog_cc="gnatgcc gcc cc"
  73 else
  74         cf_prog_cc="gcc cc"
  75 fi
  76 CF_PROG_CC($cf_prog_cc)
  77
  78 AC_PROG_CPP
  79 AC_PROG_GCC_TRADITIONAL
  80 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
  81 CF_PROG_LDCONFIG
  82
  83 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  84 dnl                             configure script by not letting us test if C++
  85 dnl                             is present, making this option necessary.
  86 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  87 AC_ARG_WITH(cxx,
  88         [  --without-cxx           do not adjust ncurses bool to match C++],
  89         [cf_with_cxx=$withval],
  90         [cf_with_cxx=yes])
  91 AC_MSG_RESULT($cf_with_cxx)
  92 if test "X$cf_with_cxx" = Xno ; then
  93         CXX=""
  94         GXX=""
  95 else
  96         # with autoconf 2.13, we can change the error to a warning:
  97         pushdef([AC_MSG_ERROR],
  98                 [AC_MSG_RESULT(no)
  99                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
 100                 cf_with_cxx=no; CXX=""; GXX="";])dnl
 101         AC_PROG_CXX
 102         popdef([AC_MSG_ERROR])dnl
 103
 104         AC_LANG_PUSH(C++)
 105         if test "x$cf_with_cxx" != xno
 106         then
 107                 # Several of the C++ configurations do not work, particularly when
 108                 # cross-compiling (20140913 -TD)
 109                 AC_MSG_CHECKING(if $CXX works)
 110
 111                 save_CPPFLAGS="$CPPFLAGS"
 112                 eval cf_includedir=${includedir}
 113                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
 114                 AC_TRY_COMPILE([
 115 #include <stdlib.h>
 116 #include <stdio.h>
 117 ],
 118                 [
 119                 printf("Hello world!\n")
 120                 ],
 121                 [cf_cxx_works=yes],
 122                 [cf_cxx_works=no])
 123                 CPPFLAGS="$save_CPPFLAGS"
 124
 125                 AC_MSG_RESULT($cf_cxx_works)
 126                 if test "x$cf_cxx_works" = xno
 127                 then
 128                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
 129                         cf_with_cxx=no; CXX=""; GXX="";
 130                 fi
 131         fi
 132         AC_LANG_POP
 133
 134         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
 135         if test "$CXX" = "g++" ; then
 136                 AC_PATH_PROG(CXX,g++)
 137         fi
 138         case "x$CXX" in
 139         (x|xg++)
 140                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
 141                 cf_with_cxx=no; CXX=""; GXX="";
 142                 ;;
 143         esac
 144 fi
 145
 146 CF_GXX_VERSION
 147 case "$GXX_VERSION" in
 148 ([[1-9]][[0-9]].*)
 149         ;;
 150 (1.*|2.[[0-6]]*)
 151         AC_MSG_WARN(templates do not work)
 152         ;;
 153 esac
 154
 155 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 156 AC_ARG_WITH(cxx-binding,
 157         [  --without-cxx-binding   do not build C++ binding and demo],
 158         [cf_with_cxx_binding=$withval],
 159         [cf_with_cxx_binding=$cf_with_cxx])
 160 AC_MSG_RESULT($cf_with_cxx_binding)
 161
 162 AC_MSG_CHECKING(if you want to build with Ada)
 163 AC_MSG_RESULT($cf_with_ada)
 164
 165 AC_MSG_CHECKING(if you want to install terminal database)
 166 AC_ARG_ENABLE(db-install,
 167         [  --disable-db-install    suppress install of terminal database],
 168         [cf_with_db_install=$enableval],
 169         [cf_with_db_install=yes])
 170 AC_MSG_RESULT($cf_with_db_install)
 171
 172 AC_MSG_CHECKING(if you want to install manpages)
 173 AC_ARG_WITH(manpages,
 174         [  --without-manpages      suppress install of manpages],
 175         [cf_with_manpages=$withval],
 176         [cf_with_manpages=yes])
 177 AC_MSG_RESULT($cf_with_manpages)
 178
 179 AC_MSG_CHECKING(if you want to build programs such as tic)
 180 AC_ARG_WITH(progs,
 181         [  --without-progs         suppress build/install with programs (e.g., tic)],
 182         [cf_with_progs=$withval],
 183         [cf_with_progs=yes])
 184 AC_MSG_RESULT($cf_with_progs)
 185
 186 if test -f "$srcdir/tack/tack.h" ; then
 187         if test "x$cross_compiling" = xyes ; then
 188                 CF_VERBOSE(ignoring tack because we are cross-compiling)
 189                 cf_with_tack=no
 190         else
 191                 AC_MSG_CHECKING(if you want to build the tack program)
 192                 AC_ARG_WITH(tack,
 193                         [  --without-tack          suppress build/install with tack program],
 194                         [cf_with_tack=$withval],
 195                         [cf_with_tack=$cf_with_progs])
 196                 AC_MSG_RESULT($cf_with_tack)
 197         fi
 198 else
 199         cf_with_tack=no
 200 fi
 201
 202 AC_MSG_CHECKING(if you want to build test-programs)
 203 AC_ARG_WITH(tests,
 204         [  --without-tests         suppress build/install with test-programs],
 205         [cf_with_tests=$withval],
 206         [cf_with_tests=yes])
 207 AC_MSG_RESULT($cf_with_tests)
 208
 209 AC_MSG_CHECKING(if you wish to install curses.h)
 210 AC_ARG_WITH(curses-h,
 211         [  --without-curses-h      install curses.h as ncurses.h only],
 212         [with_curses_h=$withval],
 213         [with_curses_h=yes])
 214 AC_MSG_RESULT($with_curses_h)
 215
 216 modules_to_build="ncurses"
 217 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
 218 test "X$cf_with_tack"  != Xno && modules_to_build="$modules_to_build tack"
 219 modules_to_build="$modules_to_build panel menu form"
 220
 221 AC_ARG_PROGRAM
 222
 223 CF_PROG_AWK
 224 CF_PROG_INSTALL
 225 CF_PROG_LINT
 226 CF_PROG_LN_S
 227
 228 AC_SYS_LONG_FILE_NAMES
 229
 230 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
 231 # of package conflict.
 232 cf_config_suffix=
 233 AC_ARG_WITH(config-suffix,
 234         [  --with-config-suffix=X  suffixes ncursesXX-config file],
 235         [case "x$withval" in
 236         (xyes|xno)
 237                 AC_MSG_WARN(expected a value for config-suffix option)
 238                 ;;
 239         (*)     cf_config_suffix="$withval"
 240                 ;;
 241         esac])
 242 AC_SUBST(cf_config_suffix)
 243
 244 # If we find pkg-config, check if we should install the ".pc" files.
 245 CF_PKG_CONFIG
 246 CF_WITH_PKG_CONFIG_LIBDIR
 247 CF_ENABLE_PC_FILES
 248 if test -z "$MAKE_PC_FILES"
 249 then
 250         AC_MSG_CHECKING(for suffix to add to pc-files)
 251 AC_ARG_WITH(pc-suffix,
 252         [  --with-pc-suffix        suffixes pc-files],
 253         [case "x$withval" in
 254         (xyes|xno)
 255                 PC_MODULE_SUFFIX=
 256                 ;;
 257         (*)     PC_MODULE_SUFFIX="$withval"
 258                 ;;
 259         esac])
 260         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
 261         AC_MSG_RESULT($PC_MODULE_SUFFIX)
 262         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
 263         AC_SUBST(PC_MODULE_SUFFIX)
 264 fi
 265
 266 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 267 AC_ARG_ENABLE(mixed-case,
 268         [  --enable-mixed-case     tic should assume mixed-case filenames],
 269         [enable_mixedcase=$enableval],
 270         [enable_mixedcase=auto])
 271 AC_MSG_RESULT($enable_mixedcase)
 272 if test "$enable_mixedcase" = "auto" ; then
 273         CF_MIXEDCASE_FILENAMES
 274 else
 275         cf_cv_mixedcase=$enable_mixedcase
 276         if test "x$enable_mixedcase" = "xyes" ; then
 277                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
 278         fi
 279 fi
 280
 281 # do this after mixed-case option (tags/TAGS is not as important as tic).
 282 AC_PROG_MAKE_SET
 283 CF_MAKE_PHONY
 284 CF_MAKE_TAGS
 285 CF_MAKEFLAGS
 286
 287 dnl These are standard among *NIX systems, but not when cross-compiling
 288 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 289 AC_CHECK_TOOL(LD, ld, ld)
 290 AC_CHECK_TOOL(AR, ar, ar)
 291 AC_CHECK_TOOL(NM, nm, nm)
 292 CF_AR_FLAGS
 293
 294 dnl Special option for use by system-builders: the install-prefix is used to
 295 dnl adjust the location into which the actual install is done, so that an
 296 dnl archive can be built without modifying the host system's configuration.
 297 AC_MSG_CHECKING(if you have specified an install-prefix)
 298 AC_ARG_WITH(install-prefix,
 299         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 300         [case "x$withval" in
 301         (xyes|xno)
 302                 ;;
 303         (*)     DESTDIR="$withval"
 304                 ;;
 305         esac])
 306 AC_MSG_RESULT($DESTDIR)
 307 AC_SUBST(DESTDIR)
 308
 309 ###############################################################################
 310 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 311 # If we're cross-compiling, allow the user to override the tools and their
 312 # options.  The configure script is oriented toward identifying the host
 313 # compiler, etc., but we need a build compiler to generate parts of the source.
 314
 315 case "$cf_cv_system_name" in
 316 (*-msvc*)
 317         LDFLAGS="$LDFLAGS user32.lib"
 318         export LDFLAGS
 319         ;;
 320 esac
 321
 322 CF_BUILD_CC
 323
 324 ###############################################################################
 325 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 326
 327 ### Options to allow the user to specify the set of libraries which are used.
 328 ### Use "--without-normal --with-shared" to allow the default model to be
 329 ### shared, for example.
 330 cf_list_models=""
 331 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 332
 333 CF_WITH_LIBTOOL
 334 if test "$with_libtool" != "no" ; then
 335
 336 cf_list_models="$cf_list_models libtool"
 337
 338 else
 339
 340 AC_MSG_CHECKING(if you want to build shared libraries)
 341 AC_ARG_WITH(shared,
 342         [  --with-shared           generate shared-libraries],
 343         [with_shared=$withval],
 344         [with_shared=no])
 345 AC_MSG_RESULT($with_shared)
 346 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
 347
 348 AC_MSG_CHECKING(if you want to build static libraries)
 349 AC_ARG_WITH(normal,
 350         [  --with-normal           generate normal-libraries (default)],
 351         [with_normal=$withval],
 352         [with_normal=yes])
 353 AC_MSG_RESULT($with_normal)
 354 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
 355
 356 AC_MSG_CHECKING(if you want to build debug libraries)
 357 AC_ARG_WITH(debug,
 358         [  --with-debug            generate debug-libraries (default)],
 359         [with_debug=$withval],
 360         [with_debug=yes])
 361 AC_MSG_RESULT($with_debug)
 362 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
 363
 364 AC_MSG_CHECKING(if you want to build profiling libraries)
 365 AC_ARG_WITH(profile,
 366         [  --with-profile          generate profile-libraries],
 367         [with_profile=$withval],
 368         [with_profile=no])
 369 AC_MSG_RESULT($with_profile)
 370 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
 371
 372 fi
 373
 374 if test "X$cf_with_cxx_binding" != Xno; then
 375 if test "x$with_shared" = "xyes"; then
 376 AC_MSG_CHECKING(if you want to build C++ shared libraries)
 377 AC_ARG_WITH(cxx-shared,
 378         [  --with-cxx-shared       generate C++ shared-libraries],
 379         [with_shared_cxx=$withval],
 380         [with_shared_cxx=no])
 381 AC_MSG_RESULT($with_shared_cxx)
 382 fi
 383 fi
 384
 385 ###############################################################################
 386
 387 AC_MSG_CHECKING(for specified models)
 388 test -z "$cf_list_models" && cf_list_models=normal
 389 dnl If we use libtool to generate libraries, then it must be the only
 390 dnl specified model.
 391 test "$with_libtool" != "no" && cf_list_models=libtool
 392 AC_MSG_RESULT($cf_list_models)
 393
 394 ### Use the first model as the default, and save its suffix for use in building
 395 ### up test-applications.
 396 AC_MSG_CHECKING(for default model)
 397 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 398 AC_MSG_RESULT($DFT_LWR_MODEL)
 399
 400 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 401
 402 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 403 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 404
 405 TICS_NAME=tic
 406 AC_SUBST(TICS_NAME)
 407
 408 TINFO_NAME=tinfo
 409 AC_SUBST(TINFO_NAME)
 410
 411 LIB_NAME=ncurses
 412 AC_SUBST(LIB_NAME)
 413
 414 LIB_DIR=../lib
 415 LIB_2ND=../../lib
 416
 417 CF_WITH_LIB_PREFIX(cf_prefix)
 418
 419 LIB_SUFFIX=
 420 AC_SUBST(LIB_SUFFIX)
 421 CF_PATHSEP
 422
 423 ###############################################################################
 424
 425 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 426 AC_ARG_WITH(termlib,
 427         [  --with-termlib          generate separate terminfo library],
 428         [with_termlib=$withval],
 429         [with_termlib=no])
 430 AC_MSG_RESULT($with_termlib)
 431
 432 AC_MSG_CHECKING(if you want to build a separate tic library)
 433 AC_ARG_WITH(ticlib,
 434         [  --with-ticlib           generate separate tic library],
 435         [with_ticlib=$withval],
 436         [with_ticlib=no])
 437 AC_MSG_RESULT($with_ticlib)
 438
 439 dnl Not all ports of gcc support the -g option
 440
 441 if test X"$CC_G_OPT" = X"" ; then
 442         CC_G_OPT='-g'
 443         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
 444 fi
 445 AC_SUBST(CC_G_OPT)
 446
 447 if test X"$CXX_G_OPT" = X"" ; then
 448         CXX_G_OPT='-g'
 449         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
 450 fi
 451 AC_SUBST(CXX_G_OPT)
 452
 453 AC_MSG_CHECKING(for default loader flags)
 454 case "$DFT_LWR_MODEL" in
 455 (libtool) LD_MODEL=''   ;;
 456 (normal)  LD_MODEL=''   ;;
 457 (debug)   LD_MODEL=$CC_G_OPT ;;
 458 (profile) LD_MODEL='-pg';;
 459 (shared)  LD_MODEL=''   ;;
 460 esac
 461 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 462 AC_MSG_RESULT($LD_MODEL)
 463
 464 case "$DFT_LWR_MODEL" in
 465 (shared)
 466 CF_ENABLE_RPATH
 467 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 468 AC_ARG_ENABLE(relink,
 469 [  --disable-relink        relink shared libraries during install],
 470 [cf_cv_do_relink=$enableval],
 471 [cf_cv_do_relink=yes])
 472 AC_MSG_RESULT($cf_cv_do_relink)
 473         ;;
 474 esac
 475
 476 # we will build libraries one-level down.
 477 rel_builddir=..
 478 CF_SHARED_OPTS
 479 for model in $cf_list_models ; do
 480         case "$model" in
 481         (libtool)
 482                 CF_WITH_LIBTOOL_OPTS
 483                 CF_WITH_EXPORT_SYMS
 484                 ;;
 485         (shared)
 486                 if test "$CC_SHARED_OPTS" = "unknown"; then
 487                         AC_ERROR(Shared libraries are not supported in this version)
 488                 fi
 489                 # workaround for inept transition to PIE vs PIC...
 490                 AC_MSG_CHECKING(if current CFLAGS link properly)
 491                 AC_TRY_LINK(
 492                         [#include <stdio.h>],
 493                         [printf("Hello work\\n");],
 494                         [cf_cflags_work=yes],
 495                         [cf_cflags_work=no])
 496                 AC_MSG_RESULT($cf_cflags_work)
 497                 if test "$cf_cflags_work" = no
 498                 then
 499                         CF_VERBOSE(try to work around by appending shared-options)
 500                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
 501                 fi
 502                 CF_WITH_VERSIONED_SYMS
 503                 ;;
 504         esac
 505 done
 506
 507 ### Checks for special libraries, must be done up-front.
 508 SHLIB_LIST=""
 509 CF_WITH_GPM
 510 if test "$with_gpm" != no ; then
 511         AC_MSG_CHECKING(if you want to load GPM dynamically)
 512         AC_ARG_WITH(dlsym,
 513                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 514                 [with_dlsym=$withval],
 515                 [with_dlsym=yes])
 516         AC_MSG_RESULT($with_dlsym)
 517         if test "x$with_dlsym" = xyes ; then
 518                 CF_FUNC_DLSYM
 519                 if test "x$with_gpm" != xyes ; then
 520                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 521                         cf_cv_gpm_soname="$with_gpm"
 522                 else
 523                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 524                 fi
 525                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
 526                 SHLIB_LIST="-ldl $SHLIB_LIST"
 527                 CF_ADD_LIB(dl,PRIVATE_LIBS)
 528         else
 529                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 530                 CF_ADD_LIB(gpm,TEST_LIBS)
 531                 CF_ADD_LIB(gpm,PRIVATE_LIBS)
 532         fi
 533         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
 534         CF_CHECK_GPM_WGETCH
 535 fi
 536
 537 CF_WITH_PCRE2
 538 CF_WITH_SYSMOUSE
 539
 540 # pretend that ncurses==ncursesw==ncursest
 541 AC_MSG_CHECKING(if you want to disable library suffixes)
 542 CF_ARG_DISABLE(lib-suffixes,
 543         [  --disable-lib-suffixes  disable library suffixes],
 544         [disable_lib_suffixes=yes],
 545         [disable_lib_suffixes=no],
 546         no)
 547 AC_MSG_RESULT($disable_lib_suffixes)
 548
 549 ### If we're building with rpath, try to link non-standard libs that way too.
 550 if test "$DFT_LWR_MODEL" = "shared" && test "x$cf_cv_enable_rpath" != xno; then
 551         CF_DISABLE_RPATH_HACK
 552 fi
 553
 554 ### Depending on the system, someone may use rpath to build ncurses but not
 555 # want users of the package to rely upon that feature.  Give those people an
 556 # option to suppress that detail from EXTRA_LDFLAGS.
 557 EXTRA_PKG_LDFLAGS="$LDFLAGS $EXTRA_LDFLAGS"
 558 if test -n "$EXTRA_PKG_LDFLAGS"
 559 then
 560         AC_MSG_CHECKING(if you want to disable extra LDFLAGS for package-scripts)
 561         CF_ARG_DISABLE(pkg-ldflags,
 562                 [  --disable-pkg-ldflags   disable extra LDFLAGS for package-scripts],
 563                 [disable_pkg_ldflags=yes],
 564                 [disable_pkg_ldflags=no],
 565                 no)
 566         AC_MSG_RESULT($disable_pkg_ldflags)
 567         test "$disable_pkg_ldflags" = yes && EXTRA_PKG_LDFLAGS=
 568 fi
 569 AC_SUBST(EXTRA_PKG_LDFLAGS)
 570
 571 ###############################################################################
 572 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 573
 574 ###     use option --with-extra-suffix to append suffix to headers and libraries
 575 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
 576 EXTRA_SUFFIX=
 577 AC_ARG_WITH(extra-suffix,
 578         [  --with-extra-suffix=X   append extra suffix to header/library paths],
 579         [case x$withval in
 580         (xno)
 581                 ;;
 582         (xyes|x)
 583                 EXTRA_SUFFIX=$cf_cv_abi_version
 584                 ;;
 585         (*)
 586                 EXTRA_SUFFIX=$withval
 587                 ;;
 588         esac
 589         ])
 590 AC_MSG_RESULT($EXTRA_SUFFIX)
 591 AC_SUBST(EXTRA_SUFFIX)
 592
 593 ###     use option --disable-overwrite to leave out the link to -lcurses
 594 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 595 AC_ARG_ENABLE(overwrite,
 596         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
 597         [with_overwrite=$enableval],
 598         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 599 AC_MSG_RESULT($with_overwrite)
 600
 601 AC_MSG_CHECKING(if external terminfo-database is used)
 602 AC_ARG_ENABLE(database,
 603         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 604         [use_database=$enableval],
 605         [use_database=yes])
 606 AC_MSG_RESULT($use_database)
 607
 608 case "$host_os" in
 609 (os2*)
 610         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 611         ;;
 612 (*)
 613         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 614         ;;
 615 esac
 616 AC_SUBST(TERMINFO_SRC)
 617
 618 NCURSES_USE_DATABASE=0
 619 if test "$use_database" != no ; then
 620         NCURSES_USE_DATABASE=1
 621
 622         AC_MSG_CHECKING(which terminfo source-file will be installed)
 623         AC_ARG_WITH(database,
 624                 [  --with-database=XXX     specify terminfo source to install],
 625                 [TERMINFO_SRC=$withval])
 626         AC_MSG_RESULT($TERMINFO_SRC)
 627
 628         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 629         AC_ARG_WITH(hashed-db,
 630                 [  --with-hashed-db        specify hashed-database library],,
 631                 [with_hashed_db=no])
 632         AC_MSG_RESULT($with_hashed_db)
 633 else
 634         with_hashed_db=no
 635 fi
 636 AC_SUBST(NCURSES_USE_DATABASE)
 637
 638 AC_MSG_CHECKING(for list of fallback descriptions)
 639 AC_ARG_WITH(fallbacks,
 640         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 641         [with_fallback=$withval],
 642         [with_fallback=])
 643 AC_MSG_RESULT($with_fallback)
 644
 645 case ".$with_fallback" in
 646 (.|.no)
 647         FALLBACK_LIST=
 648         ;;
 649 (.yes)
 650         AC_MSG_WARN(expected a list of terminal descriptions)
 651         ;;
 652 (*)
 653         FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 654         ;;
 655 esac
 656
 657 # The fallback feature in ncurses relies upon tic/infocmp outside the build
 658 # tree for generating the terminal descriptions that will be compiled into the
 659 # library.  If your toolchain is old, it may not handle current terminal
 660 # databases.  Use configure-options to point to the tools which will be used,
 661 # rather than the first ones found on the $PATH.
 662 AC_CHECK_TOOL(TIC, tic)
 663 AC_CHECK_TOOL(INFOCMP, infocmp)
 664 if test -n "$FALLBACK_LIST"
 665 then
 666         CF_WITH_PATH_PROG(TIC,     tic,     [for fallbacks], $PATH:/usr/local/ncurses/bin)
 667         CF_WITH_PATH_PROG(INFOCMP, infocmp, [for fallbacks], $PATH:/usr/local/ncurses/bin)
 668         test -z "$TIC" && FALLBACK_LIST=
 669         test -z "$INFOCMP" && FALLBACK_LIST=
 670         if test -z "$FALLBACK_LIST"
 671         then
 672                 AC_MSG_WARN(ignoring fallback option because tic/infocmp are not available)
 673         fi
 674 fi
 675 AC_SUBST(TIC)
 676 AC_SUBST(INFOCMP)
 677
 678 USE_FALLBACKS=
 679 test -z "$FALLBACK_LIST" && USE_FALLBACKS="#"
 680 AC_SUBST(FALLBACK_LIST)
 681 AC_SUBST(USE_FALLBACKS)
 682
 683 AC_MSG_CHECKING(if you want modern xterm or antique)
 684 AC_ARG_WITH(xterm-new,
 685         [  --without-xterm-new     specify if xterm terminfo should be old version],
 686         [with_xterm_new=$withval],
 687         [with_xterm_new=yes])
 688 case "$with_xterm_new" in
 689 (no) with_xterm_new=xterm-old;;
 690 (*)      with_xterm_new=xterm-new;;
 691 esac
 692 AC_MSG_RESULT($with_xterm_new)
 693 WHICH_XTERM=$with_xterm_new
 694 AC_SUBST(WHICH_XTERM)
 695
 696 case $host_os in
 697 (*linux-gnu|*cygwin|*mingw32|*msys)
 698         want_xterm_kbs=DEL
 699         ;;
 700 (*)
 701         want_xterm_kbs=BS
 702         ;;
 703 esac
 704
 705 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 706 AC_ARG_WITH(xterm-kbs,
 707         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
 708         [with_xterm_kbs=$withval],
 709         [with_xterm_kbs=BS])
 710 case x$with_xterm_kbs in
 711 (xyes|xno|xBS|xbs|x8)
 712         with_xterm_kbs=BS
 713         ;;
 714 (xDEL|xdel|x127)
 715         with_xterm_kbs=DEL
 716         ;;
 717 (*)
 718         with_xterm_kbs=$withval
 719         ;;
 720 esac
 721 AC_MSG_RESULT($with_xterm_kbs)
 722 XTERM_KBS=$with_xterm_kbs
 723 AC_SUBST(XTERM_KBS)
 724
 725 if test "x$with_xterm_kbs" != "x$want_xterm_kbs"
 726 then
 727         AC_MSG_WARN(expected --with-xterm-kbs=$want_xterm_kbs for $host_os)
 728 fi
 729
 730 MAKE_TERMINFO=
 731 if test "$use_database" = no ; then
 732         TERMINFO="${datadir}/terminfo"
 733         MAKE_TERMINFO="#"
 734 else
 735
 736 AC_MSG_CHECKING(for list of terminfo directories)
 737 CF_WITH_PATHLIST(terminfo-dirs,
 738         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 739         TERMINFO_DIRS,
 740         DATADIR/terminfo,
 741         ${datadir}/terminfo)
 742 AC_MSG_RESULT($TERMINFO_DIRS)
 743 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
 744
 745 case "x$TERMINFO" in
 746 x???:*)
 747         AC_MSG_WARN(ignoring non-directory/file TERMINFO value)
 748         unset TERMINFO
 749         ;;
 750 esac
 751
 752 AC_MSG_CHECKING(for default terminfo directory)
 753 CF_WITH_PATH(default-terminfo-dir,
 754         [  --with-default-terminfo-dir=DIR default terminfo directory],
 755         TERMINFO,
 756         DATADIR/terminfo,
 757         ${datadir}/terminfo)
 758 AC_MSG_RESULT($TERMINFO)
 759 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
 760
 761 fi
 762
 763 AC_SUBST(TERMINFO)
 764 AC_SUBST(MAKE_TERMINFO)
 765
 766 ###     use option --disable-big-core to make tic run on small machines
 767 ###     We need 4Mb, check if we can allocate 50% more than that.
 768 AC_MSG_CHECKING(if big-core option selected)
 769 AC_ARG_ENABLE(big-core,
 770         [  --disable-big-core      assume machine has little memory],
 771         [with_big_core=$enableval],
 772         [AC_TRY_RUN([
 773 #include <stdlib.h>
 774 #include <string.h>
 775 int main() {
 776         unsigned long n = 6000000L;
 777         char *s = malloc(n);
 778         if (s != 0)
 779                 s[0] = s[n-1] = 0;
 780         ${cf_cv_main_return:-return}(s == 0);
 781 }],
 782         [with_big_core=yes],
 783         [with_big_core=no],
 784         [with_big_core=no])])
 785 AC_MSG_RESULT($with_big_core)
 786 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
 787
 788 ### ISO C only guarantees 512-char strings, we have tables which load faster
 789 ### when constructed using "big" strings.  More than the C compiler, the awk
 790 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 791 AC_MSG_CHECKING(if big-strings option selected)
 792 AC_ARG_ENABLE(big-strings,
 793         [  --disable-big-strings   assume compiler has only standard-size strings],
 794         [with_big_strings=$enableval],
 795         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 796 AC_MSG_RESULT($with_big_strings)
 797
 798 USE_BIG_STRINGS=0
 799 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
 800 AC_SUBST(USE_BIG_STRINGS)
 801
 802 ###     use option --enable-termcap to compile in the termcap fallback support
 803 AC_MSG_CHECKING(if you want termcap-fallback support)
 804 AC_ARG_ENABLE(termcap,
 805         [  --enable-termcap        compile in termcap fallback support],
 806         [with_termcap=$enableval],
 807         [with_termcap=no])
 808 AC_MSG_RESULT($with_termcap)
 809
 810 NCURSES_USE_TERMCAP=0
 811 if test "x$with_termcap" != "xyes" ; then
 812         if test "$use_database" = no ; then
 813                 if test -z "$with_fallback" ; then
 814                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 815                 fi
 816         fi
 817         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
 818 else
 819
 820         if test "$with_ticlib" != no ; then
 821                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 822         fi
 823
 824         NCURSES_USE_TERMCAP=1
 825         AC_MSG_CHECKING(for list of termcap files)
 826         CF_WITH_PATHLIST(termpath,
 827                 [  --with-termpath=XXX     specify list of termcap files],
 828                 TERMPATH,
 829                 /etc/termcap:/usr/share/misc/termcap)
 830         AC_MSG_RESULT($TERMPATH)
 831         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
 832
 833         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 834         AC_MSG_CHECKING(if fast termcap-loader is needed)
 835         AC_ARG_ENABLE(getcap,
 836                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 837                 [with_getcap=$enableval],
 838                 [with_getcap=no])
 839         AC_MSG_RESULT($with_getcap)
 840         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
 841
 842         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 843         AC_ARG_ENABLE(getcap-cache,
 844                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 845                 [with_getcap_cache=$enableval],
 846                 [with_getcap_cache=no])
 847         AC_MSG_RESULT($with_getcap_cache)
 848         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
 849
 850 fi
 851 AC_SUBST(NCURSES_USE_TERMCAP)
 852
 853 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 854 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 855 AC_ARG_ENABLE(home-terminfo,
 856         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 857         [with_home_terminfo=$enableval],
 858         [with_home_terminfo=yes])
 859 AC_MSG_RESULT($with_home_terminfo)
 860 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
 861
 862 AC_MSG_CHECKING(if you want to permit root to use ncurses environment variables)
 863 AC_ARG_ENABLE(root-environ,
 864         [  --disable-root-environ  restrict root use of ncurses environment variables],
 865         [with_root_environ=$enableval],
 866         [with_root_environ=yes])
 867 AC_MSG_RESULT($with_root_environ)
 868 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if root is allowed to use ncurses environment])
 869
 870 AC_MSG_CHECKING(if you want to permit setuid programs to access all files)
 871 AC_ARG_ENABLE(root-environ,
 872         [  --disable-root-access   restrict file-access when running setuid],
 873         [with_root_access=$enableval],
 874         [with_root_access=yes])
 875 AC_MSG_RESULT($with_root_access)
 876 test "x$with_root_access" = xyes && AC_DEFINE(USE_ROOT_ACCESS,1,[Define to 1 if setuid is allowed all file-access])
 877
 878 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 879 ###   to reduce storage requirements for the terminfo database.
 880 CF_LINK_FUNCS
 881
 882 with_links=no
 883 with_symlinks=no
 884
 885 # soft links (symbolic links) are useful for some systems where hard links do
 886 # not work, or to make it simpler to copy terminfo trees around.
 887 if test "x$ac_cv_func_symlink" = xyes ; then
 888         AC_MSG_CHECKING(if tic should use symbolic links)
 889         AC_ARG_ENABLE(symlinks,
 890         [  --enable-symlinks       make tic use symbolic links not hard links],
 891         [with_symlinks=$enableval],
 892         [with_symlinks=no])
 893         AC_MSG_RESULT($with_symlinks)
 894 fi
 895
 896 # If we have hard links and did not choose to use soft links instead, there is
 897 # no reason to make this choice optional - use the hard links.
 898 if test "$with_symlinks" = no ; then
 899         AC_MSG_CHECKING(if tic should use hard links)
 900         if test "x$ac_cv_func_link" = xyes ; then
 901                 with_links=yes
 902         else
 903                 with_links=no
 904         fi
 905         AC_MSG_RESULT($with_links)
 906 fi
 907
 908 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
 909 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
 910
 911 ###   use option --enable-broken-linker to force on use of broken-linker support
 912 CF_ENABLE_BROKEN_LINKER
 913
 914 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 915 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 916 AC_ARG_ENABLE(bsdpad,
 917         [  --enable-bsdpad         recognize BSD-style prefix padding],
 918         [with_bsdpad=$enableval],
 919         [with_bsdpad=no])
 920 AC_MSG_RESULT($with_bsdpad)
 921 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
 922
 923 ###   use option --enable-widec to turn on use of wide-character support
 924 NCURSES_CH_T=chtype
 925 NCURSES_LIBUTF8=0
 926
 927 NEED_WCHAR_H=0
 928 NCURSES_MBSTATE_T=0
 929 NCURSES_WCHAR_T=0
 930 NCURSES_WINT_T=0
 931
 932 # Check to define _XOPEN_SOURCE "automatically"
 933 CPPFLAGS_before_XOPEN="$CPPFLAGS"
 934 CF_XOPEN_SOURCE(600)
 935 CPPFLAGS_after_XOPEN="$CPPFLAGS"
 936
 937 # Work around breakage on OS X
 938 CF_SIGWINCH
 939
 940 # Checks for CODESET support.
 941 AM_LANGINFO_CODESET
 942
 943 # use these variables to work around a defect in gcc's fixincludes.
 944 NCURSES_OK_WCHAR_T=
 945 NCURSES_OK_WINT_T=
 946
 947 AC_MSG_CHECKING(if you want wide-character code)
 948 AC_ARG_ENABLE(widec,
 949         [  --enable-widec          compile with wide-char/UTF-8 code],
 950         [with_widec=$enableval],
 951         [with_widec=no])
 952 AC_MSG_RESULT($with_widec)
 953
 954 NCURSES_WCWIDTH_GRAPHICS=1
 955 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
 956
 957 if test "x$with_widec" = xyes ; then
 958         if test "x$disable_lib_suffixes" = xno ; then
 959                 LIB_SUFFIX="w${LIB_SUFFIX}"
 960         fi
 961         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
 962         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
 963
 964         CF_CHECK_WCHAR_H
 965         CF_CHECK_WCWIDTH_GRAPHICS
 966         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
 967
 968         # with_overwrite=no
 969         NCURSES_CH_T=cchar_t
 970         AC_CHECK_FUNCS(putwc btowc wctob wmemchr mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 971         if test "x$ac_cv_func_putwc" != xyes ; then
 972                 CF_UTF8_LIB
 973                 if test "$cf_cv_utf8_lib" != no ; then
 974                         NCURSES_LIBUTF8=1
 975                 fi
 976         fi
 977         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 978         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 979         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 980
 981         if test "$NCURSES_MBSTATE_T" != 0; then
 982                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
 983         fi
 984 fi
 985 AC_SUBST(NCURSES_CH_T)
 986 AC_SUBST(NCURSES_LIBUTF8)
 987
 988 AC_SUBST(NEED_WCHAR_H)
 989 AC_SUBST(NCURSES_MBSTATE_T)
 990 AC_SUBST(NCURSES_WCHAR_T)
 991 AC_SUBST(NCURSES_WINT_T)
 992
 993 AC_SUBST(NCURSES_OK_WCHAR_T)
 994 AC_SUBST(NCURSES_OK_WINT_T)
 995
 996 ###   use option --disable-lp64 to allow long chtype
 997 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 998 AC_ARG_ENABLE(lp64,
 999         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
1000         [with_lp64=$enableval],
1001         [with_lp64=$cf_dft_with_lp64])
1002 AC_MSG_RESULT($with_lp64)
1003
1004 if test "x$with_lp64" = xyes ; then
1005         cf_cv_enable_lp64=1
1006 else
1007         cf_cv_enable_lp64=0
1008 fi
1009 AC_SUBST(cf_cv_enable_lp64)
1010
1011 CF_LARGEFILE
1012
1013 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
1014 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
1015 AC_ARG_ENABLE(tparm-varargs,
1016         [  --disable-tparm-varargs compile tparm() without varargs interface],
1017         [with_tparm_varargs=$enableval],
1018         [with_tparm_varargs=yes])
1019 AC_MSG_RESULT($with_tparm_varargs)
1020 NCURSES_TPARM_VARARGS=0
1021 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
1022 AC_SUBST(NCURSES_TPARM_VARARGS)
1023
1024 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
1025 if test "$with_ticlib" != no ; then
1026 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
1027 AC_ARG_ENABLE(tic-depends,
1028         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
1029         [with_tic_depends=$enableval],
1030         [with_tic_depends=yes])
1031 AC_MSG_RESULT($with_tic_depends)
1032 else
1033         with_tic_depends=no
1034 fi
1035
1036 ###   use option --enable-wattr-macros to enable wattr* macros in curses.h
1037 AC_MSG_CHECKING(if you want to enable wattr* macros)
1038 AC_ARG_ENABLE(wattr-macros,
1039         [  --enable-wattr-macros   enable wattr* macros],
1040         [with_wattr_macros=$enableval],
1041         [with_wattr_macros=no])
1042 if [[ "x$with_wattr_macros" != xyes ]]; then
1043         NCURSES_WATTR_MACROS=0
1044         AC_MSG_RESULT(no)
1045 else
1046         NCURSES_WATTR_MACROS=1
1047         AC_MSG_RESULT(yes)
1048 fi
1049 AC_SUBST(NCURSES_WATTR_MACROS)
1050
1051 CF_WITH_X11_RGB
1052
1053 ###   use option --with-bool to override bool's type
1054 AC_MSG_CHECKING(for type of bool)
1055 AC_ARG_WITH(bool,
1056         [  --with-bool=TYPE        override fallback type of bool variable],
1057         [NCURSES_BOOL="$withval"],
1058         [NCURSES_BOOL=auto])
1059 AC_MSG_RESULT($NCURSES_BOOL)
1060 AC_SUBST(NCURSES_BOOL)
1061
1062 AC_MSG_CHECKING(for alternate terminal capabilities file)
1063 AC_ARG_WITH(caps,
1064         [  --with-caps=alt         compile with alternate Caps file],
1065         [TERMINFO_CAPS=Caps.$withval],
1066         [TERMINFO_CAPS=Caps])
1067 if test ! -f "${srcdir}/include/${TERMINFO_CAPS}"
1068 then
1069         AC_MSG_WARN(file not found: "${srcdir}/include/${TERMINFO_CAPS}")
1070         TERMINFO_CAPS=Caps
1071 fi
1072 AC_MSG_RESULT($TERMINFO_CAPS)
1073 AC_SUBST(TERMINFO_CAPS)
1074
1075 ###   use option --with-chtype to override chtype's type
1076 AC_MSG_CHECKING(for type of chtype)
1077 AC_ARG_WITH(chtype,
1078         [  --with-chtype=TYPE      override type of chtype],
1079         [NCURSES_CHTYPE="$withval"],
1080         [NCURSES_CHTYPE=$cf_dft_chtype])
1081 AC_MSG_RESULT($NCURSES_CHTYPE)
1082
1083 ###   use option --with-ospeed to override ospeed's type
1084 AC_MSG_CHECKING(for type of ospeed)
1085 AC_ARG_WITH(ospeed,
1086         [  --with-ospeed=TYPE      override type of ospeed variable],
1087         [NCURSES_OSPEED="$withval"],
1088         [NCURSES_OSPEED=short])
1089 AC_MSG_RESULT($NCURSES_OSPEED)
1090 AC_SUBST(NCURSES_OSPEED)
1091
1092 ###   use option --with-mmask-t to override mmask_t's type
1093 AC_MSG_CHECKING(for type of mmask_t)
1094 AC_ARG_WITH(mmask-t,
1095         [  --with-mmask-t=TYPE     override type of mmask_t],
1096         [NCURSES_MMASK_T="$withval"],
1097         [NCURSES_MMASK_T=$cf_dft_mmask_t])
1098 AC_MSG_RESULT($NCURSES_MMASK_T)
1099
1100 ###   use option --with-ccharw-max to override CCHARW_MAX size
1101 AC_MSG_CHECKING(for size CCHARW_MAX)
1102 AC_ARG_WITH(ccharw-max,
1103         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1104         [NCURSES_CCHARW_MAX="$withval"],
1105         [NCURSES_CCHARW_MAX=$cf_dft_ccharw_max])
1106 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1107 AC_SUBST(NCURSES_CCHARW_MAX)
1108
1109 AC_CHECK_SIZEOF([signed char])
1110 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1111         NCURSES_SBOOL="signed char"
1112 else
1113         NCURSES_SBOOL="char"
1114 fi
1115 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1116 AC_ARG_ENABLE(signed-char,
1117         [  --enable-signed-char    compile using signed Boolean's in term.h],
1118         [with_signed_char=$enableval],
1119         [with_signed_char=$cf_dft_signed_char])
1120 AC_MSG_RESULT($with_signed_char)
1121 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1122 AC_SUBST(NCURSES_SBOOL)
1123
1124 ###   use option --with-tparm-arg to override tparm's argument type
1125 AC_MSG_CHECKING(for type of tparm args)
1126 AC_ARG_WITH(tparm-arg,
1127         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1128         [NCURSES_TPARM_ARG="$withval"],
1129         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1130 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1131 AC_SUBST(NCURSES_TPARM_ARG)
1132
1133 ### Enable compiling-in rcs id's
1134 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1135 AC_ARG_WITH(rcs-ids,
1136         [  --with-rcs-ids          compile-in RCS identifiers],
1137         [with_rcs_ids=$withval],
1138         [with_rcs_ids=no])
1139 AC_MSG_RESULT($with_rcs_ids)
1140 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1141
1142 ###############################################################################
1143 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1144
1145 ###############################################################################
1146 CF_HELP_MESSAGE(Extensions:)
1147
1148 ### Note that some functions (such as const) are normally disabled anyway.
1149 AC_MSG_CHECKING(if you want to build with function extensions)
1150 AC_ARG_ENABLE(ext-funcs,
1151         [  --disable-ext-funcs     disable function-extensions],
1152         [with_ext_funcs=$enableval],
1153         [with_ext_funcs=yes])
1154 AC_MSG_RESULT($with_ext_funcs)
1155 if test "x$with_ext_funcs" = xyes ; then
1156         NCURSES_EXT_FUNCS=1
1157         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1158         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1159         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1160         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1161         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1162         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1163         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1164         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1165         AC_DEFINE(HAVE_USE_EXTENDED_NAMES,1,[Define to 1 to enable use_extended_names() function in test-programs])
1166         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1167         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1168         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1169         GENERATED_EXT_FUNCS=generated
1170         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1171 else
1172         NCURSES_EXT_FUNCS=0
1173         GENERATED_EXT_FUNCS=
1174 fi
1175 AC_SUBST(NCURSES_EXT_FUNCS)
1176 AC_SUBST(GENERATED_EXT_FUNCS)
1177
1178 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1179 AC_ARG_ENABLE(sp-funcs,
1180         [  --enable-sp-funcs       enable SCREEN-extensions],
1181         [with_sp_funcs=$enableval],
1182         [with_sp_funcs=$cf_dft_ext_spfuncs])
1183 AC_MSG_RESULT($with_sp_funcs)
1184 if test "x$with_sp_funcs" = xyes ; then
1185         NCURSES_SP_FUNCS=1
1186         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1187         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1188         GENERATED_SP_FUNCS=generated
1189 else
1190         NCURSES_SP_FUNCS=0
1191         GENERATED_SP_FUNCS=
1192 fi
1193 AC_SUBST(NCURSES_SP_FUNCS)
1194 AC_SUBST(GENERATED_SP_FUNCS)
1195
1196 AC_MSG_CHECKING(if you want to build with terminal-driver)
1197 AC_ARG_ENABLE(term-driver,
1198         [  --enable-term-driver    enable terminal-driver],
1199         [with_term_driver=$enableval],
1200         [with_term_driver=no])
1201 AC_MSG_RESULT($with_term_driver)
1202 if test "x$with_term_driver" = xyes ; then
1203         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1204         if test "x$with_termlib" != xno ; then
1205                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1206         fi
1207         if test "x$with_sp_funcs" != xyes ; then
1208                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1209         fi
1210 fi
1211
1212 ###   use option --enable-const to turn on use of const beyond that in XSI.
1213 AC_MSG_CHECKING(for extended use of const keyword)
1214 AC_ARG_ENABLE(const,
1215         [  --enable-const          compile with extra/non-standard const],
1216         [with_ext_const=$enableval],
1217         [with_ext_const=$cf_dft_ext_const])
1218 AC_MSG_RESULT($with_ext_const)
1219 NCURSES_CONST='/*nothing*/'
1220 if test "x$with_ext_const" = xyes ; then
1221         NCURSES_CONST=const
1222 fi
1223 AC_SUBST(NCURSES_CONST)
1224
1225 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1226 AC_MSG_CHECKING(if you want to use extended colors)
1227 AC_ARG_ENABLE(ext-colors,
1228         [  --enable-ext-colors     compile for 256-color support],
1229         [with_ext_colors=$enableval],
1230         [with_ext_colors=$cf_dft_ext_colors])
1231 AC_MSG_RESULT($with_ext_colors)
1232 NCURSES_EXT_COLORS=0
1233 if test "x$with_ext_colors" = xyes ; then
1234         if test "x$with_widec" != xyes ; then
1235                 AC_MSG_WARN(This option applies only to wide-character library)
1236         else
1237                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1238                 CF_NCURSES_ABI_6
1239                 NCURSES_EXT_COLORS=1
1240                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1241                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1242                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1243                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1244         fi
1245 fi
1246 AC_SUBST(NCURSES_EXT_COLORS)
1247
1248 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1249 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1250 AC_ARG_ENABLE(ext-mouse,
1251         [  --enable-ext-mouse      compile for extended mouse-encoding],
1252         [with_ext_mouse=$enableval],
1253         [with_ext_mouse=$cf_dft_ext_mouse])
1254 AC_MSG_RESULT($with_ext_mouse)
1255 if test "x$with_ext_mouse" = xyes ; then
1256         CF_NCURSES_ABI_6
1257 fi
1258
1259 case $cf_cv_abi_version in
1260 (5)
1261         NCURSES_MOUSE_VERSION=1
1262         ;;
1263 (6)
1264         NCURSES_MOUSE_VERSION=2
1265         ;;
1266 ([789])
1267         NCURSES_MOUSE_VERSION=3
1268         ;;
1269 esac
1270
1271 AC_SUBST(NCURSES_MOUSE_VERSION)
1272
1273 ###   use option --enable-ext-putwin to turn on extended screendumps
1274 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1275 AC_ARG_ENABLE(ext-putwin,
1276         [  --enable-ext-putwin     compile with extended putwin/screendump],
1277         [with_ext_putwin=$enableval],
1278         [with_ext_putwin=$cf_dft_ext_putwin])
1279 AC_MSG_RESULT($with_ext_putwin)
1280 if test "x$with_ext_putwin" = xyes ; then
1281         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1282 fi
1283
1284 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1285 AC_ARG_ENABLE(no-padding,
1286         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1287         [with_no_padding=$enableval],
1288         [with_no_padding=$with_ext_funcs])
1289 AC_MSG_RESULT($with_no_padding)
1290 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1291
1292 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1293 AC_MSG_CHECKING(if you want SIGWINCH handler)
1294 AC_ARG_ENABLE(sigwinch,
1295         [  --enable-sigwinch       compile with SIGWINCH handler],
1296         [with_sigwinch=$enableval],
1297         [with_sigwinch=$with_ext_funcs])
1298 AC_MSG_RESULT($with_sigwinch)
1299 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1300
1301 ###   use option --enable-tcap-names to allow user to define new capabilities
1302 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1303 AC_ARG_ENABLE(tcap-names,
1304         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1305         [with_tcap_names=$enableval],
1306         [with_tcap_names=$with_ext_funcs])
1307 AC_MSG_RESULT($with_tcap_names)
1308 NCURSES_XNAMES=0
1309 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1310 AC_SUBST(NCURSES_XNAMES)
1311
1312 ##############################################################################
1313 CF_HELP_MESSAGE(Reentrant Code:)
1314 CF_WITH_PTHREAD
1315
1316 if test "x$with_pthread" != xno; then
1317         AC_CHECK_FUNC(pthread_kill,[
1318                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1319                 AC_ARG_ENABLE(pthreads-eintr,
1320                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1321                         [use_pthreads_eintr=$enableval],
1322                         [use_pthreads_eintr=no])
1323                 AC_MSG_RESULT($use_pthreads_eintr)
1324                 if test "x$use_pthreads_eintr" = xyes ; then
1325                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1326                 fi])
1327
1328         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1329         AC_ARG_ENABLE(weak-symbols,
1330                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1331                 [use_weak_symbols=$enableval],
1332                 [use_weak_symbols=no])
1333         AC_MSG_RESULT($use_weak_symbols)
1334         if test "x$use_weak_symbols" = xyes ; then
1335                 CF_WEAK_SYMBOLS
1336         else
1337                 cf_cv_weak_symbols=no
1338         fi
1339
1340         if test "x$cf_cv_weak_symbols" = xyes ; then
1341                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1342         fi
1343 fi
1344
1345 PTHREAD=
1346 if test "x$with_pthread" = "xyes" ; then
1347         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1348         enable_reentrant=yes
1349         if test "x$cf_cv_weak_symbols" = xyes ; then
1350                 PTHREAD=-lpthread
1351                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1352         fi
1353 fi
1354 AC_SUBST(PTHREAD)
1355
1356 # Reentrant code has to be opaque; there's little advantage to making ncurses
1357 # opaque outside of that, so there is no --enable-opaque option.  We can use
1358 # this option without --with-pthreads, but this will be always set for
1359 # pthreads.
1360 AC_MSG_CHECKING(if you want reentrant code)
1361 AC_ARG_ENABLE(reentrant,
1362         [  --enable-reentrant      compile with reentrant code],
1363         [with_reentrant=$enableval],
1364         [with_reentrant=no])
1365 AC_MSG_RESULT($with_reentrant)
1366 if test "x$with_reentrant" = xyes ; then
1367         cf_cv_enable_reentrant=1
1368         cf_cv_enable_opaque="NCURSES_INTERNALS"
1369         NCURSES_SIZE_T=int
1370         if test "x$cf_cv_weak_symbols" = xyes ; then
1371                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1372                 CF_ADD_LIB(pthread,TEST_LIBS)
1373                 CF_ADD_LIB(pthread,TEST_LIBS2)
1374                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1375         else
1376                 # when not using weak symbols but with_reentrant,
1377                 # add 't' to the library suffix on all platforms
1378                 # except cygwin, where we only do that if ALSO
1379                 # compiling with full thread support.
1380                 case "$host" in
1381                 (*cygwin* | *msys*)
1382                         if test "$with_pthread" = "yes" ; then
1383                                 if test "x$disable_lib_suffixes" = "xno" ; then
1384                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1385                                 fi
1386                         fi ;;
1387                 (*)
1388                         if test "x$disable_lib_suffixes" = "xno" ; then
1389                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1390                         fi
1391                         ;;
1392                 esac
1393         fi
1394         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1395         CF_NCURSES_ABI_6
1396 else
1397         cf_cv_enable_reentrant=0
1398         cf_cv_enable_opaque="NCURSES_OPAQUE"
1399         NCURSES_SIZE_T=$cf_dft_ordinate_type
1400 fi
1401 AC_SUBST(cf_cv_enable_reentrant)
1402 AC_SUBST(cf_cv_enable_opaque)
1403
1404 AC_SUBST(NCURSES_SIZE_T)
1405
1406 AC_MSG_CHECKING(if you want opaque curses-library structures)
1407 CF_ARG_ENABLE(opaque-curses,
1408         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1409         [enable_opaque_curses=yes],[
1410          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1411          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=$cf_dft_opaque_curses
1412         ])
1413 AC_MSG_RESULT($enable_opaque_curses)
1414
1415 test "$cf_cv_enable_reentrant" = 1 && \
1416 test "$enable_opaque_curses" = no && \
1417 AC_MSG_ERROR(reentrant configuration requires opaque library)
1418
1419 AC_MSG_CHECKING(if you want opaque form-library structures)
1420 AC_ARG_ENABLE(opaque-form,
1421         [  --enable-opaque-form    make form-library structures "opaque"],
1422         [enable_opaque_form=yes],[enable_opaque_form=no])
1423 AC_MSG_RESULT($enable_opaque_form)
1424
1425 AC_MSG_CHECKING(if you want opaque menu-library structures)
1426 AC_ARG_ENABLE(opaque-menu,
1427         [  --enable-opaque-menu    make menu-library structures "opaque"],
1428         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1429 AC_MSG_RESULT($enable_opaque_menu)
1430
1431 AC_MSG_CHECKING(if you want opaque panel-library structures)
1432 AC_ARG_ENABLE(opaque-panel,
1433         [  --enable-opaque-panel   make panel-library structures "opaque"],
1434         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1435 AC_MSG_RESULT($enable_opaque_panel)
1436
1437 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1438 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1439 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1440 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1441
1442 AC_SUBST(NCURSES_OPAQUE)
1443 AC_SUBST(NCURSES_OPAQUE_FORM)
1444 AC_SUBST(NCURSES_OPAQUE_MENU)
1445 AC_SUBST(NCURSES_OPAQUE_PANEL)
1446
1447 ### Allow using a different wrap-prefix
1448 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1449         AC_MSG_CHECKING(for prefix used to wrap public variables)
1450         AC_ARG_WITH(wrap-prefix,
1451                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1452                 [NCURSES_WRAP_PREFIX=$withval],
1453                 [NCURSES_WRAP_PREFIX=_nc_])
1454         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1455 else
1456         NCURSES_WRAP_PREFIX=_nc_
1457 fi
1458 AC_SUBST(NCURSES_WRAP_PREFIX)
1459 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1460
1461 ###############################################################################
1462 # These options are relatively safe to experiment with.
1463 CF_HELP_MESSAGE(Development Code:)
1464 AC_MSG_CHECKING(if you want all development code)
1465 AC_ARG_WITH(develop,
1466         [  --without-develop       disable development options],
1467         [with_develop=$withval],
1468         [with_develop=no])
1469 AC_MSG_RESULT($with_develop)
1470
1471 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1472 AC_MSG_CHECKING(if you want hard-tabs code)
1473 AC_ARG_ENABLE(hard-tabs,
1474         [  --enable-hard-tabs      compile with hard-tabs code],,
1475         [enable_hard_tabs=$with_develop])
1476 AC_MSG_RESULT($enable_hard_tabs)
1477 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1478
1479 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1480 AC_MSG_CHECKING(if you want limited support for xmc)
1481 AC_ARG_ENABLE(xmc-glitch,
1482         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1483         [enable_xmc_glitch=$with_develop])
1484 AC_MSG_RESULT($enable_xmc_glitch)
1485 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1486
1487 ###############################################################################
1488 # These are just experimental, probably should not be in a package:
1489 CF_HELP_MESSAGE(Experimental Code:)
1490
1491 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1492 AC_ARG_ENABLE(assumed-color,
1493         [  --disable-assumed-color do not assume anything about default-colors],
1494         [with_assumed_color=$enableval],
1495         [with_assumed_color=yes])
1496 AC_MSG_RESULT($with_assumed_color)
1497 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1498
1499 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1500 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1501 AC_ARG_ENABLE(hashmap,
1502         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1503         [with_hashmap=$enableval],
1504         [with_hashmap=yes])
1505 AC_MSG_RESULT($with_hashmap)
1506 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1507
1508 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1509 AC_MSG_CHECKING(if you want colorfgbg code)
1510 AC_ARG_ENABLE(colorfgbg,
1511         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1512         [with_colorfgbg=$enableval],
1513         [with_colorfgbg=no])
1514 AC_MSG_RESULT($with_colorfgbg)
1515 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1516
1517 ###   use option --enable-fvisibility to turn on use of gcc-specific feature
1518 AC_MSG_CHECKING(if you want to use gcc -fvisibility option)
1519 AC_ARG_ENABLE(fvisibility,
1520         [  --enable-fvisibility    compile with -fvisibility=hidden],
1521         [cf_with_fvisibility=$enableval],
1522         [cf_with_fvisibility=no])
1523 AC_MSG_RESULT($cf_with_fvisibility)
1524
1525 NCURSES_IMPEXP=
1526 NCURSES_CXX_IMPEXP=
1527 if test "x$cf_with_fvisibility" = xyes; then
1528         CF_CHECK_FVISIBILITY($CC,CFLAGS,cf_cv_fvisibility_hidden)
1529         if test "x$cf_cv_fvisibility_hidden" = xyes
1530         then
1531                 CF_ADD_CFLAGS([-fvisibility=hidden])
1532                 NCURSES_IMPEXP="__attribute__ ((visibility(\"default\")))"
1533         fi
1534         if test -n "$CXX"
1535         then
1536                 AC_LANG_PUSH(C++)
1537                 CF_CHECK_FVISIBILITY($CXX,CXXFLAGS,cf_cv_fvisibility_hidden2)
1538                 if test "x$cf_cv_fvisibility_hidden2" = xyes
1539                 then
1540                         CF_ADD_CXXFLAGS([-fvisibility=hidden])
1541                         NCURSES_CXX_IMPEXP="__attribute__ ((visibility(\"default\")))"
1542                 fi
1543                 AC_LANG_POP
1544         fi
1545 fi
1546 AC_SUBST(NCURSES_IMPEXP)
1547 AC_SUBST(NCURSES_CXX_IMPEXP)
1548
1549 ###   use option --enable-interop to turn on use of bindings used for interop
1550 AC_MSG_CHECKING(if you want interop bindings)
1551 AC_ARG_ENABLE(interop,
1552         [  --enable-interop        compile-in interop bindings],
1553         [with_exp_interop=$enableval],
1554         [with_exp_interop=$cf_dft_interop])
1555 AC_MSG_RESULT($with_exp_interop)
1556
1557 NCURSES_INTEROP_FUNCS=0
1558 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1559 AC_SUBST(NCURSES_INTEROP_FUNCS)
1560
1561
1562 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1563 AC_ARG_ENABLE(safe-sprintf,
1564         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1565         [with_safe_sprintf=$enableval],
1566         [with_safe_sprintf=no])
1567 AC_MSG_RESULT($with_safe_sprintf)
1568
1569 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1570 # when hashmap is used scroll hints are useless
1571 if test "$with_hashmap" = no ; then
1572 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1573 AC_ARG_ENABLE(scroll-hints,
1574         [  --disable-scroll-hints  compile without scroll-hints code],
1575         [with_scroll_hints=$enableval],
1576         [with_scroll_hints=yes])
1577 AC_MSG_RESULT($with_scroll_hints)
1578 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1579 fi
1580
1581 AC_MSG_CHECKING(if you want wgetch-events code)
1582 AC_ARG_ENABLE(wgetch-events,
1583         [  --enable-wgetch-events  compile with wgetch-events code],
1584         [with_wgetch_events=$enableval],
1585         [with_wgetch_events=no])
1586 AC_MSG_RESULT($with_wgetch_events)
1587 if test "x$with_wgetch_events" = xyes ; then
1588         AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1589         NCURSES_WGETCH_EVENTS=1
1590 else
1591         NCURSES_WGETCH_EVENTS=0
1592 fi
1593 AC_SUBST(NCURSES_WGETCH_EVENTS)
1594
1595 case "$cf_cv_system_name" in
1596 (*mingw32*|*mingw64*|*-msvc*)
1597         AC_MSG_CHECKING(if you want experimental-Windows driver)
1598         AC_ARG_ENABLE(exp-win32,
1599                 [  --enable-exp-win32      compile with experimental-Windows driver],
1600                 [with_exp_win32=$enableval],
1601                 [with_exp_win32=no])
1602         AC_MSG_RESULT($with_exp_win32)
1603         if test "x$with_exp_win32" = xyes
1604         then
1605                 AC_DEFINE(EXP_WIN32_DRIVER,1,[Define to 1 to compile with experimental win32 driver])
1606                 EXP_WIN32_DRIVER=1
1607                 INTERNALS_HDR='[$](INCDIR)/nc_win32.h'
1608         else
1609                 INTERNALS_HDR='[$](INCDIR)/nc_mingw.h'
1610                 EXP_WIN32_DRIVER=0
1611         fi
1612         ;;
1613 (*)
1614         EXP_WIN32_DRIVER=0
1615         INTERNALS_HDR=
1616         ;;
1617 esac
1618 AC_SUBST(EXP_WIN32_DRIVER)
1619 AC_SUBST(INTERNALS_HDR)
1620
1621 ###############################################################################
1622 CF_HELP_MESSAGE(Testing/development Options:)
1623
1624 ###     use option --disable-echo to suppress full display compiling commands
1625 CF_DISABLE_ECHO
1626 if test "x$enable_echo" = xyes; then
1627         ECHO_LINK=
1628 else
1629         ECHO_LINK='@ echo linking $@ ... ;'
1630         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1631         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1632 fi
1633 AC_SUBST(ECHO_LINK)
1634
1635 # --disable-stripping is used for debugging
1636 CF_INSTALL_OPTS
1637
1638 # If we're avoiding relinking of shared libraries during install, that is to
1639 # avoid modifying the build-tree.  For the same reason, avoid doing ranlib if
1640 # the install program has "-p" (for preserving timestamps).
1641 cf_cv_do_reranlib=yes
1642 if test "x$cf_cv_install_p" = xyes
1643 then
1644         if test "x$cf_cv_do_relink" != xyes
1645         then
1646                 cf_cv_do_reranlib=no
1647                 INSTALL_OPT_P="-p"
1648                 INSTALL_LIB="$INSTALL_LIB $INSTALL_OPT_P"
1649         fi
1650 fi
1651 AC_SUBST(INSTALL_OPT_P)
1652
1653 ###     use option --enable-warnings to turn on all gcc warnings
1654 CF_ENABLE_WARNINGS(Wno-unknown-pragmas Wswitch-enum,yes)
1655
1656 if test "x$enable_warnings" = "xyes"; then
1657         CF_ADD_ADAFLAGS(-gnatwa -gnatyg)
1658         if test "x$cf_with_cxx" = xyes ; then
1659                 CF_GXX_WARNINGS(Wno-unused)
1660         fi
1661 fi
1662 CF_ENABLE_STRING_HACKS
1663
1664 ###     use option --enable-assertions to turn on generation of assertion code
1665 AC_MSG_CHECKING(if you want to enable runtime assertions)
1666 AC_ARG_ENABLE(assertions,
1667         [  --enable-assertions     test: turn on generation of assertion code],
1668         [with_assertions=$enableval],
1669         [with_assertions=no])
1670 AC_MSG_RESULT($with_assertions)
1671 if test -n "$GCC"
1672 then
1673         if test "$with_assertions" = no
1674         then
1675                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1676         else
1677                 CF_ADD_ADAFLAGS(-gnata)
1678         fi
1679 fi
1680
1681 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1682 CF_DISABLE_LEAKS
1683 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1684
1685 ###     use option --enable-expanded to generate certain macros as functions
1686 AC_ARG_ENABLE(expanded,
1687         [  --enable-expanded       test: generate functions for certain macros],
1688         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1689
1690 ###     use option --disable-macros to suppress macros in favor of functions
1691 AC_ARG_ENABLE(macros,
1692         [  --disable-macros        test: use functions rather than macros],
1693         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1694
1695 # Normally we only add trace() to the debug-library.  Allow this to be
1696 # extended to all models of the ncurses library:
1697 cf_all_traces=no
1698 case "$CFLAGS $CPPFLAGS" in
1699 (*-DTRACE*)
1700         cf_all_traces=yes
1701         ;;
1702 esac
1703
1704 AC_MSG_CHECKING(whether to add trace feature to all models)
1705 AC_ARG_WITH(trace,
1706 [  --with-trace            test: add trace() function to all models of ncurses],
1707 [cf_with_trace=$withval],
1708 [cf_with_trace=$cf_all_traces])
1709 AC_MSG_RESULT($cf_with_trace)
1710
1711 if test "x$cf_with_trace" = xyes ; then
1712         LIB_TRACING=all
1713         ADA_TRACE=TRUE
1714         CF_ADD_CFLAGS(-DTRACE)
1715         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1716 else
1717         LIB_TRACING=DEBUG
1718         ADA_TRACE=FALSE
1719 fi
1720
1721 AC_SUBST(ADA_TRACE)
1722
1723 CF_DISABLE_GNAT_PROJECTS
1724
1725 ###     Checks for libraries.
1726 case "$cf_cv_system_name" in
1727 (*mingw32*|*mingw64*)
1728         # Note: WINVER may be a problem with Windows 10
1729         if test "x$with_exp_win32" = xyes ; then
1730                 CPPFLAGS="$CPPFLAGS -DWINVER=0x0600 -DWIN32_LEAN_AND_MEAN"
1731         else
1732                 CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1733         fi
1734         CF_CHECK_LIBSSP
1735         ;;
1736 (*)
1737 AC_CHECK_FUNC(gettimeofday,
1738         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1739
1740 AC_CHECK_LIB(bsd, gettimeofday,
1741         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1742         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1743         ;;
1744 esac
1745
1746 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1747 AC_SUBST(MATH_LIB)
1748
1749 ###     Checks for header files.
1750 AC_STDC_HEADERS
1751 AC_HEADER_DIRENT
1752 AC_HEADER_TIME
1753 CF_REGEX
1754
1755 dnl These are some other potentially nonportable headers.
1756 AC_CHECK_HEADERS( \
1757 fcntl.h \
1758 getopt.h \
1759 limits.h \
1760 locale.h \
1761 math.h \
1762 poll.h \
1763 sys/ioctl.h \
1764 sys/param.h \
1765 sys/poll.h \
1766 sys/select.h \
1767 sys/time.h \
1768 sys/times.h \
1769 unistd.h \
1770 wctype.h \
1771 )
1772
1773 CF_GETOPT_HEADER
1774
1775 CF_CHECK_ENVIRON(environ)
1776 CF_CHECK_GETENV
1777 if test "x$cf_cv_consistent_getenv" = xno && \
1778         test "x$cf_with_trace" = xyes
1779 then
1780         AC_MSG_WARN(The NCURSES_TRACE environment variable is not supported with this configuration)
1781 fi
1782
1783 CF_SYS_TIME_SELECT
1784
1785 ###     checks for compiler characteristics
1786 AC_LANG_C
1787 AC_C_CONST
1788 CF_C_INLINE(NCURSES_INLINE,1200)
1789 CF_SIG_ATOMIC_T
1790
1791 if test "$NCURSES_CHTYPE" = auto ; then
1792         CF_TYPEOF_CHTYPE
1793 else
1794         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1795 fi
1796 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1797 AC_SUBST(cf_cv_typeof_chtype)
1798
1799 CF_UNSIGNED_LITERALS
1800 cf_cv_1UL="1"
1801 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1802 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1803 AC_SUBST(cf_cv_1UL)
1804
1805 if test "$NCURSES_MMASK_T" = auto ; then
1806         cf_cv_typeof_mmask_t=long
1807 else
1808         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1809 fi
1810 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1811 AC_SUBST(cf_cv_typeof_mmask_t)
1812
1813 ###     Checks for external-data
1814 CF_ERRNO
1815 CF_LINK_DATAONLY
1816
1817 ###     Checks for library functions.
1818 AC_CHECK_FUNCS( \
1819 fpathconf \
1820 getcwd \
1821 getegid \
1822 geteuid \
1823 getopt \
1824 issetugid \
1825 localeconv \
1826 poll \
1827 putenv \
1828 remove \
1829 select \
1830 setbuf \
1831 setbuffer \
1832 setenv \
1833 setfsuid \
1834 setvbuf \
1835 sigaction \
1836 sigvec \
1837 snprintf \
1838 strdup \
1839 strstr \
1840 sysconf \
1841 tcgetpgrp \
1842 times \
1843 tsearch \
1844 vsnprintf \
1845 )
1846
1847 CF_FUNC_GETTTYNAM
1848
1849 if test "x$ac_cv_func_getopt" = xno && \
1850    test "x$cf_with_progs$cf_with_tests" != xnono; then
1851         AC_MSG_ERROR(getopt is required for building programs)
1852 fi
1853
1854 if test "x$with_safe_sprintf" = xyes
1855 then
1856         if test "x$ac_cv_func_vsnprintf" = xyes
1857         then
1858                 AC_MSG_WARN(will use vsnprintf instead of safe-sprintf option)
1859         else
1860                 AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1861         fi
1862 fi
1863
1864 if test "x$with_getcap" = "xyes" ; then
1865         CF_CGETENT
1866 fi
1867
1868 CF_ISASCII
1869 CF_STRUCT_SIGACTION
1870 CF_FUNC_NANOSLEEP
1871 CF_FUNC_TERMIOS
1872 CF_FUNC_VSSCANF
1873 CF_MKSTEMP
1874
1875 # setup for prototype of fallback for vsscanf()
1876 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1877
1878 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1879 if test "x$cross_compiling" = xyes ; then
1880         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1881 else
1882         AC_FUNC_SETVBUF_REVERSED
1883 fi
1884 AC_CHECK_TYPE(intptr_t, long)
1885 AC_CHECK_TYPE(ssize_t, int)
1886 CF_TYPE_SIGACTION
1887 CF_SIZECHANGE
1888 CF_FUNC_MEMMOVE
1889 CF_FUNC_POLL
1890 CF_VA_COPY
1891 AC_FUNC_VFORK
1892 CF_FOPEN_BIN_R
1893
1894 # special check for test/ditto.c
1895 CF_FUNC_OPENPTY
1896 if test "$cf_cv_func_openpty" != no ; then
1897         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1898         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1899         if test "x$cf_cv_lib_util" = xyes ; then
1900                 CF_ADD_LIB(util,TEST_LIBS)
1901         fi
1902 fi
1903 AC_SUBST(TEST_LIBS)
1904 AC_SUBST(TEST_LIBS2)
1905
1906 if test "$with_hashed_db" != no ; then
1907         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1908         CF_HASHED_DB($with_hashed_db)
1909 fi
1910
1911 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1912 if test -z "$cf_user_CFLAGS" && test "$enable_leaks" = yes ; then
1913         CF_STRIP_G_OPT(CFLAGS)
1914         CF_STRIP_G_OPT(CXXFLAGS)
1915 fi
1916
1917 # Just in case, check if the C compiler has a bool type.
1918 CF_BOOL_DECL(cf_cv_cc_bool_type)
1919
1920 # Check for C++ compiler characteristics (and ensure that it's there!)
1921 if test -n "$CXX" ; then
1922         AC_LANG_CPLUSPLUS
1923         CF_STDCPP_LIBRARY
1924         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1925
1926         case "$GXX_VERSION" in
1927         (1.*|2.[[0-6]]*|[[1-9]][[0-9]].*)
1928                 cf_cxx_library=yes
1929                 ;;
1930         (*-2.7*|2.7*)
1931                 CF_GPP_LIBRARY
1932                 ;;
1933         (*)
1934                 cf_cxx_library=no
1935                 ;;
1936         esac
1937
1938         AC_CHECK_HEADERS(typeinfo)
1939         CF_CXX_IOSTREAM_NAMESPACE
1940         CF_BOOL_DECL
1941         CF_BOOL_SIZE
1942         CF_ETIP_DEFINES
1943         CF_CPP_OVERRIDE
1944         CF_CPP_PARAM_INIT
1945         CF_CPP_STATIC_CAST
1946         CF_CXX_AR_FLAGS
1947 else
1948         cf_cxx_library=no
1949         cf_cv_builtin_bool=1
1950
1951         # Just because we are not configuring against C++ right now does not
1952         # mean that a user will not want to use C++.  Some distributors disable
1953         # the C++ portion of this configuration as a shortcut (or just to avoid
1954         # compiling the demo in the c++ directory).  So we need a reasonable
1955         # default for the 'bool' type.
1956         #
1957         # Caveat: since the storage of the bool type is not standardized, it
1958         # may change.
1959
1960         if test "$NCURSES_BOOL" != auto ; then
1961                 cf_cv_type_of_bool=$NCURSES_BOOL
1962                 cf_cv_header_stdbool_h=0
1963         else
1964                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1965                         CF_BOOL_SIZE
1966                 else
1967                         AC_MSG_CHECKING(for fallback type of bool)
1968                         case "$host_cpu" in
1969                         (i?86)  cf_cv_type_of_bool=char ;;
1970                         (*)     cf_cv_type_of_bool=int  ;;
1971                         esac
1972                         AC_MSG_RESULT($cf_cv_type_of_bool)
1973                 fi
1974         fi
1975 fi
1976 AC_SUBST(CXXLIBS)
1977
1978 # If the C compiler did not declare bool, and we did not determine that the C++
1979 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1980 # ncurses library use the same type as C++ bool.  Note that this allows one to
1981 # specify the type of bool in a configure-script option and postpone
1982 # integration with the C++ compiler provided that the types are compatible.
1983 USE_CXX_BOOL=1
1984 if test "$cf_cv_cc_bool_type" = 1
1985 then
1986         # oops: C has a bool.  Unlikely, but C++ could differ.
1987         USE_CXX_BOOL=0
1988 elif test "$cf_cv_builtin_bool" = 0
1989 then
1990         # C++ has no bool
1991         USE_CXX_BOOL=0
1992 else
1993         # this is the normal case
1994         USE_CXX_BOOL='defined(__cplusplus)'
1995 fi
1996 AC_SUBST(USE_CXX_BOOL)
1997
1998 CF_HELP_MESSAGE(Ada Binding Options:)
1999
2000 dnl If the Ada95 source-tree is present, add that to the build unless it will
2001 dnl not work, or was not requested.
2002 if test -f "${srcdir}/Ada95/Makefile.in" ; then
2003
2004 dnl libtool does not know anything about GNAT, though a change made in 1998
2005 dnl provided for it "someday".  Disable the ada subtree if we are using
2006 dnl libtool -TD 20070714
2007         if test "$cf_with_ada" != "no" ; then
2008                 if test "$with_libtool" != "no"; then
2009                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
2010                         cf_with_ada=no
2011                 fi
2012         fi
2013
2014 dnl Check for availability of GNU Ada Translator (GNAT).
2015 dnl At the moment we support no other Ada compiler.
2016         if test "$cf_with_ada" != "no" ; then
2017                 CF_PROG_GNAT
2018                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
2019                         CF_ADD_ADAFLAGS(-gnatpn)
2020                         CF_FIXUP_ADAFLAGS
2021
2022                         CF_GNATPREP_OPT_T
2023
2024                         CF_GNAT_GENERICS
2025                         CF_GNAT_SIGINT
2026                         CF_GNAT_PROJECTS
2027
2028                         CF_WITH_ADA_COMPILER
2029
2030                         cf_ada_package=terminal_interface
2031                         AC_SUBST(cf_ada_package)
2032
2033                         CF_WITH_ADA_INCLUDE
2034                         CF_WITH_ADA_OBJECTS
2035                         CF_WITH_ADA_SHAREDLIB
2036
2037                         # allow the Ada binding to be renamed
2038                         CF_WITH_ADA_LIBNAME(AdaCurses)
2039                 fi
2040         fi
2041 else
2042         cf_with_ada=no
2043 fi
2044
2045 # do this "late" to avoid conflict with header-checks
2046 if test "x$with_widec" = xyes ; then
2047         AC_CHECK_SIZEOF(wchar_t)
2048         # cross-compiling to mingw can run into the problem that attempting to
2049         # link with the regex library fails, causing the test to not set this to
2050         # a number.  "recent" autoconf does not address this problem either -TD
2051         if test -z "$ac_cv_sizeof_wchar_t"
2052         then
2053                 CF_VERBOSE(test failed (assume 2))
2054                 sed /SIZEOF_WCHAR_T/d confdefs.h >confdefs.tmp
2055                 mv confdefs.tmp confdefs.h
2056                 echo "#define SIZEOF_WCHAR_T 2" >>confdefs.h
2057         fi
2058 fi
2059
2060 ### Construct the ncurses library-subsets, if any, from this set of keywords:
2061 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
2062 ###
2063 ### ticlib modules may be a separate library, otherwise contained in termlib.
2064 ### termlib modules may be a separate library, otherwise contained in ncurses.
2065 ###
2066 ### The of "+" or " " between the tokens controls the way the script
2067 ### chooses to split module lists into libraries.
2068 ###
2069 ### (see CF_LIB_RULES).
2070 AC_MSG_CHECKING(for library subsets)
2071 LIB_SUBSETS=
2072
2073 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
2074         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
2075         if test "$with_ticlib" != no ; then
2076                 LIB_SUBSETS="${LIB_SUBSETS} "
2077         else
2078                 LIB_SUBSETS="${LIB_SUBSETS}+"
2079         fi
2080 fi
2081
2082 LIB_SUBSETS="${LIB_SUBSETS}termlib"
2083 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
2084
2085 if test "$with_termlib" != no ; then
2086         LIB_SUBSETS="${LIB_SUBSETS} "
2087 else
2088         LIB_SUBSETS="${LIB_SUBSETS}+"
2089 fi
2090
2091 LIB_SUBSETS="${LIB_SUBSETS}base"
2092
2093 # Most term-driver calls are to tinfo, but some like init_pair are to the
2094 # base library (so it resides in base).
2095 if test "$with_term_driver" != no ; then
2096         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
2097         case "$cf_cv_system_name" in
2098         (*mingw32*|*mingw64*)
2099                 if test "x$with_exp_win32" = xyes ; then
2100                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32"
2101                 else
2102                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
2103                 fi
2104                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
2105                 ;;
2106         (*)
2107                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
2108                 ;;
2109         esac
2110 elif test "x$with_exp_win32" = xyes ; then
2111         case "$cf_cv_system_name" in
2112         (*mingw32*|*mingw64*)
2113                 LIB_SUBSETS="${LIB_SUBSETS}+port_win32"
2114                 ;;
2115         (*)
2116                 ;;
2117         esac
2118 fi
2119
2120 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
2121 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
2122
2123 AC_MSG_RESULT($LIB_SUBSETS)
2124
2125 ### Construct the list of include-directories to be generated
2126 CF_INCLUDE_DIRS
2127 CF_ADA_INCLUDE_DIRS
2128
2129 ### Build up pieces for makefile rules
2130 AC_MSG_CHECKING(default library suffix)
2131 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
2132 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
2133 AC_MSG_RESULT($DFT_ARG_SUFFIX)
2134
2135 AC_MSG_CHECKING(default library-dependency suffix)
2136 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
2137 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
2138 AC_MSG_RESULT($DFT_DEP_SUFFIX)
2139
2140 AC_MSG_CHECKING(default object directory)
2141 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
2142 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
2143 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
2144
2145 if test "x$cf_with_cxx" = xyes ; then
2146 AC_MSG_CHECKING(c++ library-dependency suffix)
2147 if test "$with_libtool" != "no"; then
2148         # libtool thinks it can make c++ shared libraries (perhaps only g++)
2149         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2150 elif test "$with_shared_cxx" != "no"; then
2151         # also for g++ users...
2152         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2153 else
2154         # we normally make a static library because C/C++ library rules differ
2155         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
2156 fi
2157 AC_MSG_RESULT($CXX_LIB_SUFFIX)
2158 AC_SUBST(CXX_LIB_SUFFIX)
2159 fi
2160
2161 # do not want -ldl in build except as needed for -lncurses dependency
2162 if test "x$with_dlsym" = xyes ; then
2163 if test "$DFT_LWR_MODEL" = shared || \
2164    test "$DFT_LWR_MODEL" = libtool ; then
2165         CF_REMOVE_LIB(LIBS,$LIBS,dl)
2166 fi
2167 fi
2168 ### Set up low-level terminfo dependencies for makefiles.
2169
2170 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
2171 # do not need libdl
2172 TICS_LIST=
2173 if test "x$with_dlsym" = xyes ; then
2174         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
2175 fi
2176
2177 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
2178 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
2179 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
2180 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
2181 then
2182         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
2183 fi
2184 AC_SUBST(USE_ARG_SUFFIX)
2185 AC_SUBST(USE_CFG_SUFFIX)
2186 AC_SUBST(USE_LIB_SUFFIX)
2187
2188 if test "$with_ticlib" != no ; then
2189
2190         if test "x$with_ticlib" != xyes ; then
2191                 TICS_NAME=$with_ticlib
2192                 TICS_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2193                 TICS_ARG_SUFFIX="${with_ticlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2194                 TICS_DEP_SUFFIX="${with_ticlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2195                 TICS_LIB_SUFFIX="${with_ticlib}"
2196         else
2197                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
2198                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
2199                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
2200                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
2201         fi
2202         TICS_LDFLAGS="-L${LIB_DIR}"
2203         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
2204 else
2205         TICS_SUFFIX=${DFT_LIB_SUFFIX}
2206         TICS_LDFLAGS="-L${LIB_DIR}"
2207         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2208 fi
2209 AC_SUBST(TICS_ARG_SUFFIX)
2210 AC_SUBST(TICS_DEP_SUFFIX)
2211 AC_SUBST(TICS_LIB_SUFFIX)
2212 AC_SUBST(TICS_LDFLAGS)
2213 AC_SUBST(TICS_LIBS)
2214
2215 if test "$with_termlib" != no ; then
2216
2217         if test "x$with_termlib" != xyes ; then
2218                 TINFO_NAME=$with_termlib
2219                 TINFO_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2220                 TINFO_ARG_SUFFIX="${with_termlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2221                 TINFO_DEP_SUFFIX="${with_termlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2222                 TINFO_LIB_SUFFIX="${with_termlib}"
2223         else
2224                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2225                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2226                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2227                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2228         fi
2229
2230         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2231         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2232         if test "$DFT_LWR_MODEL" = "libtool"; then
2233                 TEST_ARGS="${TEST_DEPS}"
2234                 TEST_ARG2="${TEST_DEP2}"
2235                 TINFO_LDFLAGS="-L${LIB_DIR}"
2236                 TINFO_LIBS="$TEST_ARGS"
2237                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2238                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2239         else
2240                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2241                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2242                 if test "x$with_term_driver" != xno ; then
2243                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2244                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2245                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2246                 else
2247                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2248                         TINFO_LIBS="$TEST_ARGS"
2249                 fi
2250                 TINFO_LDFLAGS="-L${LIB_DIR}"
2251                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2252         fi
2253 else
2254         # the next lines are needed for linking libtic over libncurses
2255         TINFO_NAME=${LIB_NAME}
2256         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2257         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2258         if test "x$with_tic_depends" = xyes ; then
2259                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2260         else
2261                 TICS_LIST="$SHLIB_LIST"
2262         fi
2263
2264         TINFO_LDFLAGS="-L${LIB_DIR}"
2265         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2266 fi
2267
2268 if test "$DFT_LWR_MODEL" = shared ; then
2269         case "$cf_cv_system_name" in
2270         (cygwin*|msys*)
2271                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2272                 TINFO_SUFFIX=.dll
2273                 ;;
2274         esac
2275 fi
2276
2277 AC_SUBST(TINFO_ARG_SUFFIX)
2278 AC_SUBST(TINFO_DEP_SUFFIX)
2279 AC_SUBST(TINFO_LIB_SUFFIX)
2280 AC_SUBST(TINFO_LDFLAGS)
2281 AC_SUBST(TINFO_LIBS)
2282
2283 if test "x$with_dlsym" = xyes ; then
2284         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2285 fi
2286
2287 if test "$DFT_LWR_MODEL" = "libtool"; then
2288         OBJEXT=lo
2289 fi
2290
2291 # needed for Ada95
2292 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2293 AC_SUBST(TINFO_LDFLAGS2)
2294
2295 case "$DFT_LWR_MODEL" in
2296 (normal|debug|profile)
2297         CF_LDFLAGS_STATIC
2298         ;;
2299 esac
2300
2301 AC_MSG_CHECKING(where we will install curses.h)
2302 AC_SUBST(includesubdir)
2303 includesubdir=
2304 if test "$with_overwrite" = no && \
2305  { test "x$includedir" = 'x${prefix}/include' || \
2306    test "x$includedir" = "x${prefix}/include"; }
2307 then
2308         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2309 fi
2310 AC_MSG_RESULT(${includedir}${includesubdir})
2311
2312 ### Resolve a conflict between normal and wide-curses by forcing applications
2313 ### that will need libutf8 to add it to their configure script.
2314 if test "$with_overwrite" != no ; then
2315 if test "$NCURSES_LIBUTF8" = 1 ; then
2316         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2317         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2318 fi
2319 fi
2320 WITH_OVERWRITE=$with_overwrite
2321
2322 ### At least on MinGW a shared library build without libtool
2323 ### requires adding the additional libs to the link list.
2324 case "$cf_cv_system_name" in
2325 (*mingw32*|*mingw64*)
2326         if test "$DFT_LWR_MODEL" != "libtool"; then
2327            SHLIB_LIST="$SHLIB_LIST ${LIBS}"
2328         fi
2329         ;;
2330 *)      ;;
2331 esac
2332
2333 AC_SUBST(WITH_OVERWRITE)
2334 AC_SUBST(TICS_LIST)
2335 AC_SUBST(TINFO_LIST)
2336 AC_SUBST(SHLIB_LIST)
2337
2338 # used to separate tack out of the tree
2339 NCURSES_TREE=
2340 AC_SUBST(NCURSES_TREE)
2341
2342 ### predefined stuff for the test programs
2343 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2344
2345 # pkgsrc uses these
2346 CF_WITH_LIB_BASENAME(FORM_NAME,form)
2347 CF_WITH_LIB_BASENAME(MENU_NAME,menu)
2348 CF_WITH_LIB_BASENAME(PANEL_NAME,panel)
2349 CF_WITH_LIB_BASENAME(CXX_NAME,cxx,ncurses++)
2350
2351 ### Construct the list of subdirectories for which we'll customize makefiles
2352 ### with the appropriate compile-rules.
2353
2354 CF_SRC_MODULES($modules_to_build)
2355
2356 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2357    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/src/library.gpr:Ada95/src/library.gpr.in"
2358    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2359    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2360 fi
2361
2362 CF_DIRS_TO_MAKE
2363
2364 # symbols that differ when compiling Ada95 by itself.
2365 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2366 AC_SUBST(NCURSES_SHLIB2)
2367
2368 # values to use as strings
2369 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2370
2371 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2372
2373 ### Define substitutions for header files to avoid name-pollution
2374 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2375 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2376 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2377 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2378
2379 ################################################################################
2380 test "x$use_database" = xyes && \
2381 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2382
2383 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2384 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2385
2386 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2387 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2388 fi
2389 AC_SUBST(cross_compiling)
2390
2391 if test "x$cf_with_tests" != xno ; then
2392         MAKE_TESTS=
2393 else
2394         MAKE_TESTS="#"
2395 fi
2396 AC_SUBST(MAKE_TESTS)
2397
2398 ADAHTML_DIR=../../doc/html/ada
2399 AC_SUBST(ADAHTML_DIR)
2400
2401 # workaround for OS/2 (20151017)
2402 case "$cf_cv_system_name" in
2403 (os2*)
2404         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2405         ;;
2406 (*)
2407         LIBTOOL_OPTS_CXX=
2408         ;;
2409 esac
2410 AC_SUBST(LIBTOOL_OPTS_CXX)
2411
2412 # workaround for g++ versus Solaris (20131116)
2413 case "$cf_cv_system_name" in
2414 (solaris2*)
2415         case "x$CPPFLAGS" in
2416         (*-D_XOPEN_SOURCE_EXTENDED*)
2417                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2418                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2419                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2420                 ;;
2421         esac
2422         ;;
2423 esac
2424
2425 # Help to automatically enable the extended curses features when using either
2426 # the *-config or the ".pc" files by adding defines.
2427 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2428 PKG_CFLAGS=
2429 for cf_loop1 in $CPPFLAGS_after_XOPEN
2430 do
2431         cf_found=no
2432         for cf_loop2 in $CPPFLAGS_before_XOPEN
2433         do
2434                 if test "x$cf_loop1" = "x$cf_loop2"
2435                 then
2436                         cf_found=yes
2437                         break
2438                 fi
2439         done
2440         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2441 done
2442 AC_MSG_RESULT($PKG_CFLAGS)
2443 AC_SUBST(PKG_CFLAGS)
2444
2445 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2446 case "x$NCURSES_OSPEED" in
2447 (*short*)
2448         cf_compatible=1
2449         ;;
2450 (*)
2451         cf_compatible=0
2452         ;;
2453 esac
2454 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2455
2456 case "x$cf_cv_typeof_chtype" in
2457 (xshort|xint|xlong)
2458         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2459         ;;
2460 esac
2461
2462 case "x$cf_cv_typeof_mmask_t" in
2463 (xshort|xint|xlong)
2464         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2465         ;;
2466 esac
2467
2468 # substitute into misc/Makefile to suppress
2469 # (un)install.data from the
2470 # (un)install rules.
2471 if test "x$cf_with_db_install" = "xno"; then
2472         MISC_INSTALL_DATA=
2473         MISC_UNINSTALL_DATA=
2474 else
2475         MISC_INSTALL_DATA=install.data
2476         MISC_UNINSTALL_DATA=uninstall.data
2477 fi
2478 AC_SUBST(MISC_INSTALL_DATA)
2479 AC_SUBST(MISC_UNINSTALL_DATA)
2480
2481 if test "x$cf_with_db_install" = "xno" || test "x$TERMINFO_SRC" = "xno"; then
2482         MAKE_DATABASE="#"
2483 else
2484         MAKE_DATABASE="$MAKE_TERMINFO"
2485 fi
2486 AC_SUBST(MAKE_DATABASE)
2487
2488 dnl Override the package used for exported symbols
2489 if test -n "$PACKAGE"
2490 then
2491         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2492         export PACKAGE
2493         echo "package: $PACKAGE"
2494 fi
2495
2496 UNALTERED_SYMS=
2497 cf_filter_syms=no
2498
2499 if test -n "$RESULTING_SYMS"
2500 then
2501         cf_filter_syms=$cf_dft_filter_syms
2502         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_version)
2503 fi
2504
2505 if test "x$WILDCARD_SYMS" = xno
2506 then
2507         cf_filter_syms=yes
2508 fi
2509
2510 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2511
2512 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2513 if test "$cf_filter_syms" = yes
2514 then
2515         RESULTING_SYMS=resulting.map
2516 fi
2517 AC_SUBST(UNALTERED_SYMS)
2518
2519 if test "x$cross_compiling" = xyes ; then
2520         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2521         CHECK_BUILD="#"
2522 else
2523         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2524         CHECK_BUILD=
2525 fi
2526 AC_SUBST(ADAGEN_LDFLAGS)
2527 AC_SUBST(CHECK_BUILD)
2528 AC_SUBST(PRIVATE_LIBS)
2529
2530 # This is used for the *-config script and *.pc data files.
2531 CF_LD_SEARCHPATH
2532
2533 AC_DEFINE(HAVE_CURSES_DATA_BOOLNAMES,1,[definition needed for in-tree build of tack])
2534
2535 AC_OUTPUT( \
2536         include/MKterm.h.awk \
2537         include/curses.head:include/curses.h.in \
2538         include/ncurses_dll.h \
2539         include/termcap.h \
2540         include/unctrl.h \
2541         $SUB_MAKEFILES \
2542         Makefile,[
2543 if test "x$cf_with_tests" != xno ; then
2544         CF_PRG_RULES(["$srcdir/test/mk-test.awk" INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2545 fi
2546 CF_LIB_RULES($SRC_SUBDIRS)
2547
2548 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2549 if test -z "$USE_OLD_MAKERULES" ; then
2550         $AWK -f "$srcdir/Ada95/mk-1st.awk" <"$srcdir/Ada95/src/modules" >>Ada95/src/Makefile
2551 fi
2552 fi
2553 ],[
2554 ### Special initialization commands, used to pass information from the
2555 ### configuration-run into config.status
2556
2557 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2558 AWK="$AWK"
2559 CXX_NAME="$CXX_NAME"
2560 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2561 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2562 ECHO_LD="$ECHO_LD"
2563 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2564 FORM_NAME="$FORM_NAME"
2565 LDCONFIG="$LDCONFIG"
2566 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2567 LIB_NAME="$LIB_NAME"
2568 LIB_PREFIX="$LIB_PREFIX"
2569 LIB_SUBSETS="$LIB_SUBSETS"
2570 LIB_SUFFIX="$LIB_SUFFIX"
2571 LIB_TRACING="$LIB_TRACING"
2572 LN_S="$LN_S"
2573 MAKE_TERMINFO="$MAKE_TERMINFO"
2574 MENU_NAME="$MENU_NAME"
2575 NCURSES_MAJOR="$NCURSES_MAJOR"
2576 NCURSES_MINOR="$NCURSES_MINOR"
2577 NCURSES_OSPEED="$NCURSES_OSPEED"
2578 NCURSES_PATCH="$NCURSES_PATCH"
2579 PANEL_NAME="$PANEL_NAME"
2580 SRC_SUBDIRS="$SRC_SUBDIRS"
2581 TERMINFO="$TERMINFO"
2582 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2583 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2584 TICS_NAME="$TICS_NAME"
2585 TICS_SUFFIX="$TICS_SUFFIX"
2586 TIC_PATH="$TIC_PATH"
2587 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2588 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2589 TINFO_NAME="$TINFO_NAME"
2590 TINFO_SUFFIX="$TINFO_SUFFIX"
2591 UNALTERED_SYMS="$UNALTERED_SYMS"
2592 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2593 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2594 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2595 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2596 WILDCARD_SYMS="$WILDCARD_SYMS"
2597 WITH_CURSES_H="$with_curses_h"
2598 WITH_ECHO="${enable_echo:=yes}"
2599 WITH_OVERWRITE="$with_overwrite"
2600 cf_LIST_MODELS="$cf_list_models"
2601 cf_cv_VERSION_GNATMAKE=$cf_cv_VERSION_GNATMAKE
2602 cf_cv_VERSION_GPRBUILD=$cf_cv_VERSION_GPRBUILD
2603 cf_cv_abi_version="$cf_cv_abi_version"
2604 cf_cv_do_relink="$cf_cv_do_relink"
2605 cf_cv_do_reranlib="$cf_cv_do_reranlib"
2606 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2607 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2608 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2609 cf_cv_make_PHONY="$cf_cv_make_PHONY"
2610 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2611 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2612 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2613 cf_cv_rel_version="$cf_cv_rel_version"
2614 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2615 cf_cv_shared_soname='$cf_cv_shared_soname'
2616 cf_cv_shlib_version="$cf_cv_shlib_version"
2617 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2618 cf_cv_system_name="$cf_cv_system_name"
2619 cf_cv_term_driver="$with_term_driver"
2620 cf_with_ada="$cf_with_ada"
2621 cf_with_cxx_binding="$cf_with_cxx_binding"
2622 cf_with_db_install="$cf_with_db_install"
2623 cf_with_manpages="$cf_with_manpages"
2624 cf_with_tests="$cf_with_tests"
2625 host="$host"
2626 target="$target"
2627 with_shared_cxx="$with_shared_cxx"
2628
2629 ],cat)dnl
2630 ${MAKE:-make} preinstall