ncurses 5.7 - patch 20100515
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2009,2010 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: configure.in,v 1.491 2010/05/15 21:40:14 tom Exp $
32 dnl Process this file with autoconf to produce a configure script.
33 dnl
34 dnl See http://invisible-island.net/autoconf/ for additional information.
35 dnl
36 dnl ---------------------------------------------------------------------------
37 AC_PREREQ(2.13.20020210)
38 AC_REVISION($Revision: 1.491 $)
39 AC_INIT(ncurses/base/lib_initscr.c)
40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
41
42 CF_TOP_BUILDDIR
43 CF_SUBST_NCURSES_VERSION
44
45 CF_WITH_REL_VERSION(NCURSES)
46 CF_WITH_ABI_VERSION
47
48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
49 AC_ARG_WITH(system-type,
50 [  --with-system-type=XXX  test: override derived host system-type],
51 [AC_MSG_WARN(overriding system type to $withval)
52  cf_cv_system_name=$withval])
53
54 ###     Save the given $CFLAGS to allow user-override.
55 cf_user_CFLAGS="$CFLAGS"
56
57 ###     Default install-location
58 CF_CFG_DEFAULTS
59
60 ###     Checks for programs.
61 AC_PROG_CC
62 CF_GCC_VERSION
63
64 AC_PROG_CPP
65 AC_PROG_GCC_TRADITIONAL
66 CF_PROG_CC_C_O(CC)
67 AC_ISC_POSIX
68 CF_ANSI_CC_REQD
69 CF_PROG_EXT
70 CF_PROG_LDCONFIG
71
72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
73 dnl                             configure script by not letting us test if C++
74 dnl                             is present, making this option necessary.
75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
76 AC_ARG_WITH(cxx,
77         [  --without-cxx           do not adjust ncurses bool to match C++],
78         [cf_with_cxx=$withval],
79         [cf_with_cxx=yes])
80 AC_MSG_RESULT($cf_with_cxx)
81 if test "X$cf_with_cxx" = Xno ; then
82         CXX=""
83         GXX=""
84 else
85         # with autoconf 2.13, we can change the error to a warning:
86         pushdef([AC_MSG_ERROR],
87                 [AC_MSG_RESULT(no)
88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
90         AC_PROG_CXX
91         popdef([AC_MSG_ERROR])dnl
92         # autoconf 2.5x removed the error - by hardcoding it to g++.
93         if test "$CXX" = "g++" ; then
94                 AC_PATH_PROG(CXX,g++)
95         fi
96         if test "$CXX" = "g++" ; then
97                 AC_MSG_WARN(ignoring hardcoded g++)
98                 cf_with_cxx=no; CXX=""; GXX="";
99         fi
100 fi
101
102 CF_GXX_VERSION
103 case $GXX_VERSION in
104 1*|2.[[0-6]]*)
105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
106         # cf_cxx_library=no
107         AC_MSG_WARN(templates do not work)
108         ;;
109 esac
110
111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
112 AC_ARG_WITH(cxx-binding,
113         [  --without-cxx-binding   do not build C++ binding and demo],
114         [cf_with_cxx_binding=$withval],
115         [cf_with_cxx_binding=$cf_with_cxx])
116 AC_MSG_RESULT($cf_with_cxx_binding)
117
118 AC_MSG_CHECKING(if you want to build with Ada95)
119 AC_ARG_WITH(ada,
120         [  --without-ada           suppress check for Ada95, don't build demo],
121         [cf_with_ada=$withval],
122         [cf_with_ada=yes])
123 AC_MSG_RESULT($cf_with_ada)
124
125 AC_MSG_CHECKING(if you want to install manpages)
126 AC_ARG_WITH(manpages,
127         [  --without-manpages      suppress install of manpages],
128         [cf_with_manpages=$withval],
129         [cf_with_manpages=yes])
130 AC_MSG_RESULT($cf_with_manpages)
131
132 AC_MSG_CHECKING(if you want to build programs such as tic)
133 AC_ARG_WITH(progs,
134         [  --without-progs         suppress build with programs (e.g., tic)],
135         [cf_with_progs=$withval],
136         [cf_with_progs=yes])
137 AC_MSG_RESULT($cf_with_progs)
138
139 AC_MSG_CHECKING(if you wish to install curses.h)
140 AC_ARG_WITH(curses-h,
141         [  --without-curses-h      install curses.h as ncurses.h only],
142         [with_curses_h=$withval],
143         [with_curses_h=yes])
144 AC_MSG_RESULT($with_curses_h)
145
146 modules_to_build="ncurses"
147 if test "X$cf_with_progs" != Xno ; then
148 modules_to_build="$modules_to_build progs tack"
149 fi
150 modules_to_build="$modules_to_build panel menu form"
151
152 AC_ARG_PROGRAM
153
154 CF_PROG_AWK
155 CF_PROG_EGREP
156 CF_PROG_INSTALL
157 CF_PROG_LINT
158 AC_PROG_LN_S
159
160 AC_SYS_LONG_FILE_NAMES
161
162 # if we find pkg-config, check if we should install the ".pc" files.
163 CF_PKG_CONFIG
164
165 if test "$PKG_CONFIG" != no ; then
166         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
167
168         # Leave this as something that can be overridden in the environment.
169         if test -z "$PKG_CONFIG_LIBDIR" ; then
170                 PKG_CONFIG_LIBDIR=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`/lib/pkgconfig
171         fi
172         PKG_CONFIG_LIBDIR=`echo "$PKG_CONFIG_LIBDIR" | sed -e 's/^://' -e 's/:.*//'`
173         if test -n "$PKG_CONFIG_LIBDIR" && test -d "$PKG_CONFIG_LIBDIR" ; then
174                 AC_ARG_ENABLE(pc-files,
175                         [  --enable-pc-files       generate and install .pc files for pkg-config],
176                         [enable_pc_files=$enableval],
177                         [enable_pc_files=no])
178                 AC_MSG_RESULT($enable_pc_files)
179         else
180                 AC_MSG_RESULT(no)
181                 AC_MSG_WARN(did not find library $PKG_CONFIG_LIBDIR)
182                 enable_pc_files=no
183         fi
184 fi
185 AC_SUBST(PKG_CONFIG_LIBDIR)
186
187 AC_MSG_CHECKING(if we should assume mixed-case filenames)
188 AC_ARG_ENABLE(mixed-case,
189         [  --enable-mixed-case     tic should assume mixed-case filenames],
190         [enable_mixedcase=$enableval],
191         [enable_mixedcase=auto])
192 AC_MSG_RESULT($enable_mixedcase)
193 if test "$enable_mixedcase" = "auto" ; then
194     CF_MIXEDCASE_FILENAMES
195 else
196     cf_cv_mixedcase=$enable_mixedcase
197     if test "$enable_mixedcase" = "yes" ; then
198         AC_DEFINE(MIXEDCASE_FILENAMES)
199     fi
200 fi
201
202 # do this after mixed-case option (tags/TAGS is not as important as tic).
203 AC_PROG_MAKE_SET
204 CF_MAKE_TAGS
205 CF_MAKEFLAGS
206
207 dnl These are standard among *NIX systems, but not when cross-compiling
208 AC_CHECK_TOOL(RANLIB, ranlib, ':')
209 AC_CHECK_TOOL(LD, ld, ld)
210 AC_CHECK_TOOL(AR, ar, ar)
211 CF_AR_FLAGS
212
213 dnl Special option for use by system-builders: the install-prefix is used to
214 dnl adjust the location into which the actual install is done, so that an
215 dnl archive can be built without modifying the host system's configuration.
216 AC_MSG_CHECKING(if you have specified an install-prefix)
217 AC_ARG_WITH(install-prefix,
218         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
219         [case "$withval" in #(vi
220         yes|no) #(vi
221                 ;;
222         *)      DESTDIR="$withval"
223                 ;;
224         esac])
225 AC_MSG_RESULT($DESTDIR)
226 AC_SUBST(DESTDIR)
227
228 ###############################################################################
229 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
230 # If we're cross-compiling, allow the user to override the tools and their
231 # options.  The configure script is oriented toward identifying the host
232 # compiler, etc., but we need a build compiler to generate parts of the source.
233 CF_BUILD_CC
234
235 ###############################################################################
236 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
237
238 ### Options to allow the user to specify the set of libraries which are used.
239 ### Use "--without-normal --with-shared" to allow the default model to be
240 ### shared, for example.
241 cf_list_models=""
242 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
243
244 CF_WITH_LIBTOOL
245 if test "$with_libtool" != "no" ; then
246
247 cf_list_models="$cf_list_models libtool"
248
249 else
250
251 AC_MSG_CHECKING(if you want to build shared libraries)
252 AC_ARG_WITH(shared,
253         [  --with-shared           generate shared-libraries],
254         [with_shared=$withval],
255         [with_shared=no])
256 AC_MSG_RESULT($with_shared)
257 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
258
259 AC_MSG_CHECKING(if you want to build static libraries)
260 AC_ARG_WITH(normal,
261         [  --with-normal           generate normal-libraries (default)],
262         [with_normal=$withval],
263         [with_normal=yes])
264 AC_MSG_RESULT($with_normal)
265 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
266
267 AC_MSG_CHECKING(if you want to build debug libraries)
268 AC_ARG_WITH(debug,
269         [  --with-debug            generate debug-libraries (default)],
270         [with_debug=$withval],
271         [with_debug=yes])
272 AC_MSG_RESULT($with_debug)
273 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
274
275 AC_MSG_CHECKING(if you want to build profiling libraries)
276 AC_ARG_WITH(profile,
277         [  --with-profile          generate profile-libraries],
278         [with_profile=$withval],
279         [with_profile=no])
280 AC_MSG_RESULT($with_profile)
281 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
282
283 fi
284
285 ###############################################################################
286
287 AC_MSG_CHECKING(for specified models)
288 test -z "$cf_list_models" && cf_list_models=normal
289 dnl If we use libtool to generate libraries, then it must be the only
290 dnl specified model.
291 test "$with_libtool" != "no" && cf_list_models=libtool
292 AC_MSG_RESULT($cf_list_models)
293
294 ### Use the first model as the default, and save its suffix for use in building
295 ### up test-applications.
296 AC_MSG_CHECKING(for default model)
297 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
298 AC_MSG_RESULT($DFT_LWR_MODEL)
299
300 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
301
302 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
303 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
304
305 TICS_NAME=tic
306 AC_SUBST(TICS_NAME)
307
308 TINFO_NAME=tinfo
309 AC_SUBST(TINFO_NAME)
310
311 LIB_NAME=ncurses
312 AC_SUBST(LIB_NAME)
313
314 LIB_DIR=../lib
315 LIB_2ND=../../lib
316
317 CF_LIB_PREFIX(cf_prefix)
318 LIB_PREFIX=$cf_prefix
319 AC_SUBST(LIB_PREFIX)
320
321 LIB_SUFFIX=
322 AC_SUBST(LIB_SUFFIX)
323
324 ###############################################################################
325
326 AC_MSG_CHECKING(if you want to build a separate terminfo library)
327 AC_ARG_WITH(termlib,
328         [  --with-termlib          generate separate terminfo library],
329         [with_termlib=$withval],
330         [with_termlib=no])
331 AC_MSG_RESULT($with_termlib)
332
333 AC_MSG_CHECKING(if you want to build a separate tic library)
334 AC_ARG_WITH(ticlib,
335         [  --with-ticlib           generate separate tic library],
336         [with_ticlib=$withval],
337         [with_ticlib=no])
338 AC_MSG_RESULT($with_ticlib)
339
340 ### Checks for special libraries, must be done up-front.
341 SHLIB_LIST=""
342 CF_WITH_GPM
343 if test "$with_gpm" != no ; then
344         AC_MSG_CHECKING(if you want to load GPM dynamically)
345         AC_ARG_WITH(dlsym,
346                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
347                 [with_dlsym=$withval],
348                 [with_dlsym=yes])
349         AC_MSG_RESULT($with_dlsym)
350         if test "$with_dlsym" = yes ; then
351                 CF_FUNC_DLSYM
352                 if test "$with_gpm" != yes ; then
353                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
354                         cf_cv_gpm_soname="$with_gpm"
355                 else
356                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
357                 fi
358                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
359                 SHLIB_LIST="-ldl $SHLIB_LIST"
360         else
361                 SHLIB_LIST="-lgpm $SHLIB_LIST"
362                 TEST_LIBS="-lgpm $TEST_LIBS"
363         fi
364         AC_DEFINE(HAVE_LIBGPM)
365         CF_CHECK_GPM_WGETCH
366 fi
367
368 CF_WITH_SYSMOUSE
369
370 dnl Not all ports of gcc support the -g option
371
372 if test X"$CC_G_OPT" = X"" ; then
373         CC_G_OPT='-g'
374         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
375 fi
376 AC_SUBST(CC_G_OPT)
377
378 if test X"$CXX_G_OPT" = X"" ; then
379         CXX_G_OPT='-g'
380         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
381 fi
382 AC_SUBST(CXX_G_OPT)
383
384 AC_MSG_CHECKING(for default loader flags)
385 case $DFT_LWR_MODEL in
386 libtool) LD_MODEL=''   ;;
387 normal)  LD_MODEL=''   ;;
388 debug)   LD_MODEL=$CC_G_OPT ;;
389 profile) LD_MODEL='-pg';;
390 shared)  LD_MODEL=''   ;;
391 esac
392 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
393 AC_MSG_RESULT($LD_MODEL)
394
395 case $DFT_LWR_MODEL in
396 shared)
397 CF_ENABLE_RPATH
398 AC_MSG_CHECKING(if shared libraries should be relinked during install)
399 AC_ARG_ENABLE(relink,
400 [  --disable-relink        relink shared libraries during install],
401 [cf_cv_do_relink=$enableval],
402 [cf_cv_do_relink=yes])
403 AC_MSG_RESULT($cf_cv_do_relink)
404         ;;
405 esac
406
407 CF_SHARED_OPTS
408 if test "$CC_SHARED_OPTS" = "unknown"; then
409         for model in $cf_list_models; do
410                 if test "$model" = "shared"; then
411                         AC_ERROR(Shared libraries are not supported in this version)
412                 fi
413         done
414 fi
415
416 ###############################################################################
417 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
418
419 ###     use option --disable-overwrite to leave out the link to -lcurses
420 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
421 AC_ARG_ENABLE(overwrite,
422         [  --disable-overwrite     leave out the link to -lcurses],
423         [with_overwrite=$enableval],
424         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
425 AC_MSG_RESULT($with_overwrite)
426
427 AC_MSG_CHECKING(if external terminfo-database is used)
428 AC_ARG_ENABLE(database,
429         [  --disable-database      do not use terminfo, only fallbacks/termcap],
430         [use_database=$enableval],
431         [use_database=yes])
432 AC_MSG_RESULT($use_database)
433
434 case $host_os in #(vi
435 os2*) #(vi
436         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
437         ;;
438 *) #(vi
439         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
440         ;;
441 esac
442 AC_SUBST(TERMINFO_SRC)
443
444 CF_PATHSEP
445 if test "$use_database" != no ; then
446         AC_DEFINE(USE_DATABASE)
447
448         AC_MSG_CHECKING(which terminfo source-file will be installed)
449         AC_ARG_WITH(database,
450                 [  --with-database=XXX     specify terminfo source to install],
451                 [TERMINFO_SRC=$withval])
452         AC_MSG_RESULT($TERMINFO_SRC)
453
454         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
455         AC_ARG_WITH(hashed-db,
456                 [  --with-hashed-db        specify hashed-database library],,
457                 [with_hashed_db=no])
458         AC_MSG_RESULT($with_hashed_db)
459 else
460         with_hashed_db=no
461 fi
462
463 AC_MSG_CHECKING(for list of fallback descriptions)
464 AC_ARG_WITH(fallbacks,
465         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
466         [with_fallback=$withval],
467         [with_fallback=])
468 AC_MSG_RESULT($with_fallback)
469 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
470 AC_SUBST(FALLBACK_LIST)
471
472 AC_MSG_CHECKING(if you want modern xterm or antique)
473 AC_ARG_WITH(xterm-new,
474         [  --without-xterm-new     specify if xterm terminfo should be old version],
475         [with_xterm_new=$withval],
476         [with_xterm_new=yes])
477 case $with_xterm_new in
478 no)     with_xterm_new=xterm-old;;
479 *)      with_xterm_new=xterm-new;;
480 esac
481 AC_MSG_RESULT($with_xterm_new)
482 WHICH_XTERM=$with_xterm_new
483 AC_SUBST(WHICH_XTERM)
484
485 MAKE_TERMINFO=
486 if test "$use_database" = no ; then
487         TERMINFO="${datadir}/terminfo"
488         MAKE_TERMINFO="#"
489 else
490
491 AC_MSG_CHECKING(for list of terminfo directories)
492 CF_WITH_PATHLIST(terminfo-dirs,
493         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
494         TERMINFO_DIRS,
495         DATADIR/terminfo,
496         ${datadir}/terminfo)
497 AC_MSG_RESULT($TERMINFO_DIRS)
498 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
499
500 AC_MSG_CHECKING(for default terminfo directory)
501 CF_WITH_PATH(default-terminfo-dir,
502         [  --with-default-terminfo-dir=DIR default terminfo directory],
503         TERMINFO,
504         DATADIR/terminfo,
505         ${datadir}/terminfo)
506 AC_MSG_RESULT($TERMINFO)
507 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
508
509 fi
510
511 AC_SUBST(TERMINFO)
512 AC_SUBST(MAKE_TERMINFO)
513
514 ###     use option --disable-big-core to make tic run on small machines
515 ###     We need 4Mb, check if we can allocate 50% more than that.
516 AC_MSG_CHECKING(if big-core option selected)
517 AC_ARG_ENABLE(big-core,
518         [  --disable-big-core      assume machine has little memory],
519         [with_big_core=$enableval],
520         [AC_TRY_RUN([
521 #include <stdlib.h>
522 #include <string.h>
523 int main() {
524         unsigned long n = 6000000L;
525         char *s = malloc(n);
526         if (s != 0)
527                 s[0] = s[n-1] = 0;
528         ${cf_cv_main_return:-return}(s == 0);
529 }],
530         [with_big_core=yes],
531         [with_big_core=no],
532         [with_big_core=no])])
533 AC_MSG_RESULT($with_big_core)
534 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
535
536 ### ISO C only guarantees 512-char strings, we have tables which load faster
537 ### when constructed using "big" strings.  More than the C compiler, the awk
538 ### program is a limit on most vendor UNIX systems.  Check that we can build.
539 AC_MSG_CHECKING(if big-strings option selected)
540 AC_ARG_ENABLE(big-strings,
541         [  --disable-big-strings   assume compiler has only standard-size strings],
542         [with_big_strings=$enableval],
543         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
544 AC_MSG_RESULT($with_big_strings)
545
546 USE_BIG_STRINGS=0
547 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
548 AC_SUBST(USE_BIG_STRINGS)
549
550 ###     use option --enable-termcap to compile in the termcap fallback support
551 AC_MSG_CHECKING(if you want termcap-fallback support)
552 AC_ARG_ENABLE(termcap,
553         [  --enable-termcap        compile in termcap fallback support],
554         [with_termcap=$enableval],
555         [with_termcap=no])
556 AC_MSG_RESULT($with_termcap)
557
558 if test "$with_termcap" != "yes" ; then
559         if test "$use_database" = no ; then
560                 if test -z "$with_fallback" ; then
561                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
562                 fi
563         fi
564         AC_DEFINE(PURE_TERMINFO)
565 else
566
567 if test "$with_ticlib" != no ; then
568         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
569 fi
570
571 AC_DEFINE(USE_TERMCAP)
572 AC_MSG_CHECKING(for list of termcap files)
573 CF_WITH_PATHLIST(termpath,
574         [  --with-termpath=XXX     specify list of termcap files],
575         TERMPATH,
576         /etc/termcap:/usr/share/misc/termcap)
577 AC_MSG_RESULT($TERMPATH)
578 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
579
580 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
581 AC_MSG_CHECKING(if fast termcap-loader is needed)
582 AC_ARG_ENABLE(getcap,
583         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
584         [with_getcap=$enableval],
585         [with_getcap=no])
586 AC_MSG_RESULT($with_getcap)
587 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
588
589 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
590 AC_ARG_ENABLE(getcap-cache,
591         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
592         [with_getcap_cache=$enableval],
593         [with_getcap_cache=no])
594 AC_MSG_RESULT($with_getcap_cache)
595 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
596
597 fi
598
599 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
600 AC_MSG_CHECKING(if ~/.terminfo is wanted)
601 AC_ARG_ENABLE(home-terminfo,
602         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
603         [with_home_terminfo=$enableval],
604         [with_home_terminfo=yes])
605 AC_MSG_RESULT($with_home_terminfo)
606 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
607
608 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
609 AC_ARG_ENABLE(root-environ,
610         [  --disable-root-environ  restrict environment when running as root],
611         [with_root_environ=$enableval],
612         [with_root_environ=yes])
613 AC_MSG_RESULT($with_root_environ)
614 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
615
616 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
617 ###   to reduce storage requirements for the terminfo database.
618 CF_LINK_FUNCS
619
620 with_links=no
621 with_symlinks=no
622
623 # soft links (symbolic links) are useful for some systems where hard links do
624 # not work, or to make it simpler to copy terminfo trees around.
625 if test "$ac_cv_func_symlink" = yes ; then
626     AC_MSG_CHECKING(if tic should use symbolic links)
627     AC_ARG_ENABLE(symlinks,
628         [  --enable-symlinks       make tic use symbolic links not hard links],
629         [with_symlinks=$enableval],
630         [with_symlinks=no])
631     AC_MSG_RESULT($with_symlinks)
632 fi
633
634 # If we have hard links and did not choose to use soft links instead, there is
635 # no reason to make this choice optional - use the hard links.
636 if test "$with_symlinks" = no ; then
637     AC_MSG_CHECKING(if tic should use hard links)
638     if test "$ac_cv_func_link" = yes ; then
639         with_links=yes
640     else
641         with_links=no
642     fi
643     AC_MSG_RESULT($with_links)
644 fi
645
646 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
647 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
648
649 ###   use option --enable-broken-linker to force on use of broken-linker support
650 AC_MSG_CHECKING(if you want broken-linker support code)
651 AC_ARG_ENABLE(broken_linker,
652         [  --enable-broken_linker  compile with broken-linker support code],
653         [with_broken_linker=$enableval],
654         [with_broken_linker=${BROKEN_LINKER-no}])
655 AC_MSG_RESULT($with_broken_linker)
656
657 BROKEN_LINKER=0
658 if test "$with_broken_linker" = yes ; then
659         AC_DEFINE(BROKEN_LINKER)
660         BROKEN_LINKER=1
661 elif test "$DFT_LWR_MODEL" = shared ; then
662         case $cf_cv_system_name in #(vi
663         cygwin*)
664                 AC_DEFINE(BROKEN_LINKER)
665                 BROKEN_LINKER=1
666                 CF_VERBOSE(cygwin linker is broken anyway)
667                 ;;
668         esac
669 fi
670 AC_SUBST(BROKEN_LINKER)
671
672 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
673 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
674 AC_ARG_ENABLE(bsdpad,
675         [  --enable-bsdpad         recognize BSD-style prefix padding],
676         [with_bsdpad=$enableval],
677         [with_bsdpad=no])
678 AC_MSG_RESULT($with_bsdpad)
679 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
680
681 ###   use option --enable-widec to turn on use of wide-character support
682 NCURSES_CH_T=chtype
683 NCURSES_LIBUTF8=0
684
685 NEED_WCHAR_H=0
686 NCURSES_MBSTATE_T=0
687 NCURSES_WCHAR_T=0
688 NCURSES_WINT_T=0
689
690 # Check to define _XOPEN_SOURCE "automatically"
691 CF_XOPEN_SOURCE(500)
692
693 # Work around breakage on OS X
694 CF_SIGWINCH
695
696 # Checks for CODESET support.
697 AM_LANGINFO_CODESET
698
699 # use these variables to work around a defect in gcc's fixincludes.
700 NCURSES_OK_WCHAR_T=
701 NCURSES_OK_WINT_T=
702
703 AC_MSG_CHECKING(if you want wide-character code)
704 AC_ARG_ENABLE(widec,
705         [  --enable-widec          compile with wide-char/UTF-8 code],
706         [with_widec=$enableval],
707         [with_widec=no])
708 AC_MSG_RESULT($with_widec)
709 if test "$with_widec" = yes ; then
710         LIB_SUFFIX="w${LIB_SUFFIX}"
711         AC_DEFINE(USE_WIDEC_SUPPORT)
712
713         case "$CFLAGS $CPPFLAGS" in #(vi
714         *-D_XOPEN_SOURCE=500) #(vi
715                 ;;
716         *)
717                 CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
718                 ;;
719         esac
720
721         # with_overwrite=no
722         NCURSES_CH_T=cchar_t
723         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
724         if test "$ac_cv_func_putwc" != yes ; then
725                 CF_UTF8_LIB
726                 if test "$cf_cv_utf8_lib" != no ; then
727                         NCURSES_LIBUTF8=1
728                 fi
729         fi
730         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
731         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
732         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
733
734         if test "$NCURSES_MBSTATE_T" != 0; then
735                 AC_DEFINE(NEED_MBSTATE_T_DEF)
736         fi
737 fi
738 AC_SUBST(NCURSES_CH_T)
739 AC_SUBST(NCURSES_LIBUTF8)
740
741 AC_SUBST(NEED_WCHAR_H)
742 AC_SUBST(NCURSES_MBSTATE_T)
743 AC_SUBST(NCURSES_WCHAR_T)
744 AC_SUBST(NCURSES_WINT_T)
745
746 AC_SUBST(NCURSES_OK_WCHAR_T)
747 AC_SUBST(NCURSES_OK_WINT_T)
748
749 ###   use option --disable-lp64 to allow long chtype
750 case $cf_cv_abi_version in
751 [[345]]*)
752         default_with_lp64=no
753         ;;
754 *)
755         default_with_lp64=yes
756         ;;
757 esac
758
759 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
760 AC_ARG_ENABLE(lp64,
761         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
762         [with_lp64=$enableval],
763         [with_lp64=$default_with_lp64])
764 AC_MSG_RESULT($with_lp64)
765
766 if test "$with_lp64" = yes ; then
767         cf_cv_enable_lp64=1
768 else
769         cf_cv_enable_lp64=0
770 fi
771 AC_SUBST(cf_cv_enable_lp64)
772
773 CF_LARGEFILE
774
775 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
776 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
777 AC_ARG_ENABLE(tparm-varargs,
778         [  --disable-tparm-varargs compile tparm() without varargs interface],
779         [with_tparm_varargs=$enableval],
780         [with_tparm_varargs=yes])
781 AC_MSG_RESULT($with_tparm_varargs)
782 NCURSES_TPARM_VARARGS=0
783 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
784 AC_SUBST(NCURSES_TPARM_VARARGS)
785
786 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
787 if test "$with_ticlib" != no ; then
788 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
789 AC_ARG_ENABLE(tic-depends,
790         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
791         [with_tic_depends=$enableval],
792         [with_tic_depends=yes])
793 AC_MSG_RESULT($with_tic_depends)
794 else
795         with_tic_depends=no
796 fi
797
798 ###   use option --with-bool to override bool's type
799 AC_MSG_CHECKING(for type of bool)
800 AC_ARG_WITH(bool,
801         [  --with-bool=TYPE        override fallback type of bool variable],
802         [NCURSES_BOOL="$withval"],
803         [NCURSES_BOOL=auto])
804 AC_MSG_RESULT($NCURSES_BOOL)
805 AC_SUBST(NCURSES_BOOL)
806
807 AC_MSG_CHECKING(for alternate terminal capabilities file)
808 AC_ARG_WITH(caps,
809         [  --with-caps=alt         compile with alternate Caps file],
810         [TERMINFO_CAPS=Caps.$withval],
811         [TERMINFO_CAPS=Caps])
812 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
813 AC_MSG_RESULT($TERMINFO_CAPS)
814 AC_SUBST(TERMINFO_CAPS)
815
816 ###   use option --with-chtype to override chtype's type
817 AC_MSG_CHECKING(for type of chtype)
818 AC_ARG_WITH(chtype,
819         [  --with-chtype=TYPE      override type of chtype],
820         [NCURSES_CHTYPE="$withval"],
821         [NCURSES_CHTYPE=auto])
822 AC_MSG_RESULT($NCURSES_CHTYPE)
823
824 ###   use option --with-ospeed to override ospeed's type
825 AC_MSG_CHECKING(for type of ospeed)
826 AC_ARG_WITH(ospeed,
827         [  --with-ospeed=TYPE      override type of ospeed variable],
828         [NCURSES_OSPEED="$withval"],
829         [NCURSES_OSPEED=short])
830 AC_MSG_RESULT($NCURSES_OSPEED)
831 AC_SUBST(NCURSES_OSPEED)
832
833 ###   use option --with-mmask-t to override mmask_t's type
834 AC_MSG_CHECKING(for type of mmask_t)
835 AC_ARG_WITH(mmask-t,
836         [  --with-mmask-t=TYPE     override type of mmask_t],
837         [NCURSES_MMASK_T="$withval"],
838         [NCURSES_MMASK_T=auto])
839 AC_MSG_RESULT($NCURSES_MMASK_T)
840
841 ###   use option --with-ccharw-max to override CCHARW_MAX size
842 AC_MSG_CHECKING(for size CCHARW_MAX)
843 AC_ARG_WITH(ccharw-max,
844         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
845         [NCURSES_CCHARW_MAX="$withval"],
846         [NCURSES_CCHARW_MAX=5])
847 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
848 AC_SUBST(NCURSES_CCHARW_MAX)
849
850 ### Enable compiling-in rcs id's
851 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
852 AC_ARG_WITH(rcs-ids,
853         [  --with-rcs-ids          compile-in RCS identifiers],
854         [with_rcs_ids=$withval],
855         [with_rcs_ids=no])
856 AC_MSG_RESULT($with_rcs_ids)
857 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
858
859 ###############################################################################
860 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
861
862 ###############################################################################
863 CF_HELP_MESSAGE(Extensions:)
864
865 ### Note that some functions (such as const) are normally disabled anyway.
866 AC_MSG_CHECKING(if you want to build with function extensions)
867 AC_ARG_ENABLE(ext-funcs,
868         [  --disable-ext-funcs     disable function-extensions],
869         [with_ext_funcs=$enableval],
870         [with_ext_funcs=yes])
871 AC_MSG_RESULT($with_ext_funcs)
872 if test "$with_ext_funcs" = yes ; then
873         NCURSES_EXT_FUNCS=1
874         AC_DEFINE(HAVE_CURSES_VERSION)
875         AC_DEFINE(HAVE_HAS_KEY)
876         AC_DEFINE(HAVE_RESIZETERM)
877         AC_DEFINE(HAVE_RESIZE_TERM)
878         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
879         AC_DEFINE(HAVE_WRESIZE)
880         AC_DEFINE(NCURSES_EXT_FUNCS)
881         GENERATED_EXT_FUNCS=generated
882 else
883         NCURSES_EXT_FUNCS=0
884         GENERATED_EXT_FUNCS=
885 fi
886 AC_SUBST(NCURSES_EXT_FUNCS)
887 AC_SUBST(GENERATED_EXT_FUNCS)
888
889 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
890 AC_ARG_ENABLE(sp-funcs,
891         [  --enable-sp-funcs       enable experimental SCREEN-extensions],
892         [with_sp_funcs=$enableval],
893         [with_sp_funcs=no])
894 AC_MSG_RESULT($with_sp_funcs)
895 if test "$with_sp_funcs" = yes ; then
896         NCURSES_SP_FUNCS=1
897         AC_DEFINE(NCURSES_SP_FUNCS)
898         GENERATED_SP_FUNCS=generated
899 else
900         NCURSES_SP_FUNCS=0
901         GENERATED_SP_FUNCS=
902 fi
903 AC_SUBST(NCURSES_SP_FUNCS)
904 AC_SUBST(GENERATED_SP_FUNCS)
905
906 AC_MSG_CHECKING(if you want to build with experimental terminal-driver)
907 AC_ARG_ENABLE(term-driver,
908         [  --enable-term-driver    enable experimental terminal-driver],
909         [with_term_driver=$enableval],
910         [with_term_driver=no])
911 AC_MSG_RESULT($with_term_driver)
912 if test "$with_term_driver" = yes ; then
913         AC_DEFINE(USE_TERM_DRIVER)
914         if test "$with_sp_funcs" != yes ; then
915                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
916         fi
917 fi
918
919 ###   use option --enable-const to turn on use of const beyond that in XSI.
920 AC_MSG_CHECKING(for extended use of const keyword)
921 AC_ARG_ENABLE(const,
922         [  --enable-const          compile with extra/non-standard const],
923         [with_ext_const=$enableval],
924         [with_ext_const=no])
925 AC_MSG_RESULT($with_ext_const)
926 NCURSES_CONST='/*nothing*/'
927 if test "$with_ext_const" = yes ; then
928         NCURSES_CONST=const
929 fi
930 AC_SUBST(NCURSES_CONST)
931
932 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
933 AC_MSG_CHECKING(if you want to use extended colors)
934 AC_ARG_ENABLE(ext-colors,
935         [  --enable-ext-colors     compile for 256-color support],
936         [with_ext_colors=$enableval],
937         [with_ext_colors=no])
938 AC_MSG_RESULT($with_ext_colors)
939 NCURSES_EXT_COLORS=0
940 if test "$with_ext_colors" = yes ; then
941         if test "$with_widec" != yes ; then
942                 AC_MSG_ERROR(This option applies only to wide-character library)
943         else
944                 # cannot be ABI 5 since it changes sizeof(cchar_t)
945                 CF_NCURSES_ABI_6
946         fi
947         NCURSES_EXT_COLORS=1
948         AC_DEFINE(NCURSES_EXT_COLORS)
949 fi
950 AC_SUBST(NCURSES_EXT_COLORS)
951
952 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
953 AC_MSG_CHECKING(if you want to use extended mouse encoding)
954 AC_ARG_ENABLE(ext-mouse,
955         [  --enable-ext-mouse      compile for extended mouse-encoding],
956         [with_ext_mouse=$enableval],
957         [with_ext_mouse=no])
958 AC_MSG_RESULT($with_ext_mouse)
959 NCURSES_MOUSE_VERSION=1
960 if test "$with_ext_mouse" = yes ; then
961         NCURSES_MOUSE_VERSION=2
962         CF_NCURSES_ABI_6
963 fi
964 AC_SUBST(NCURSES_MOUSE_VERSION)
965
966 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
967 AC_ARG_ENABLE(no-padding,
968         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
969         [with_no_padding=$enableval],
970         [with_no_padding=$with_ext_funcs])
971 AC_MSG_RESULT($with_no_padding)
972 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
973
974 AC_CHECK_SIZEOF([signed char], 0)
975 if test "$ac_cv_sizeof_signed_char" = 1 ; then
976         NCURSES_SBOOL="signed char"
977 else
978         NCURSES_SBOOL="char"
979 fi
980 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
981 AC_ARG_ENABLE(signed-char,
982         [  --enable-signed-char    compile using signed Boolean's in term.h],
983         [with_signed_char=$enableval],
984         [with_signed_char=no])
985 AC_MSG_RESULT($with_signed_char)
986 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
987 AC_SUBST(NCURSES_SBOOL)
988
989 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
990 AC_MSG_CHECKING(if you want SIGWINCH handler)
991 AC_ARG_ENABLE(sigwinch,
992         [  --enable-sigwinch       compile with SIGWINCH handler],
993         [with_sigwinch=$enableval],
994         [with_sigwinch=$with_ext_funcs])
995 AC_MSG_RESULT($with_sigwinch)
996 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
997
998 ###   use option --enable-tcap-names to allow user to define new capabilities
999 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1000 AC_ARG_ENABLE(tcap-names,
1001         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1002         [with_tcap_names=$enableval],
1003         [with_tcap_names=$with_ext_funcs])
1004 AC_MSG_RESULT($with_tcap_names)
1005 NCURSES_XNAMES=0
1006 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
1007 AC_SUBST(NCURSES_XNAMES)
1008
1009 ###############################################################################
1010 # These options are relatively safe to experiment with.
1011 CF_HELP_MESSAGE(Development Code:)
1012 AC_MSG_CHECKING(if you want all development code)
1013 AC_ARG_WITH(develop,
1014         [  --without-develop       disable development options],
1015         [with_develop=$withval],
1016         [with_develop=no])
1017 AC_MSG_RESULT($with_develop)
1018
1019 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1020 AC_MSG_CHECKING(if you want hard-tabs code)
1021 AC_ARG_ENABLE(hard-tabs,
1022         [  --enable-hard-tabs      compile with hard-tabs code],,
1023         [enable_hard_tabs=$with_develop])
1024 AC_MSG_RESULT($enable_hard_tabs)
1025 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
1026
1027 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1028 AC_MSG_CHECKING(if you want limited support for xmc)
1029 AC_ARG_ENABLE(xmc-glitch,
1030         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1031         [enable_xmc_glitch=$with_develop])
1032 AC_MSG_RESULT($enable_xmc_glitch)
1033 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
1034
1035 ###############################################################################
1036 # These are just experimental, probably should not be in a package:
1037 CF_HELP_MESSAGE(Experimental Code:)
1038
1039 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1040 AC_ARG_ENABLE(assumed-color,
1041         [  --disable-assumed-color do not assume anything about default-colors],
1042         [with_assumed_color=$enableval],
1043         [with_assumed_color=yes])
1044 AC_MSG_RESULT($with_assumed_color)
1045 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
1046
1047 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1048 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1049 AC_ARG_ENABLE(hashmap,
1050         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1051         [with_hashmap=$enableval],
1052         [with_hashmap=yes])
1053 AC_MSG_RESULT($with_hashmap)
1054 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
1055
1056 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1057 AC_MSG_CHECKING(if you want colorfgbg code)
1058 AC_ARG_ENABLE(colorfgbg,
1059         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1060         [with_colorfgbg=$enableval],
1061         [with_colorfgbg=no])
1062 AC_MSG_RESULT($with_colorfgbg)
1063 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
1064
1065 ###   use option --enable-interop to turn on use of bindings used for interop
1066 AC_MSG_CHECKING(if you want interop bindings)
1067 AC_ARG_ENABLE(interop,
1068         [  --enable-interop        compile-in experimental interop bindings],
1069         [with_exp_interop=$enableval],
1070         [with_exp_interop=no])
1071 AC_MSG_RESULT($with_exp_interop)
1072
1073 NCURSES_INTEROP_FUNCS=0
1074 test "$with_exp_interop" = yes && NCURSES_INTEROP_FUNCS=1
1075 AC_SUBST(NCURSES_INTEROP_FUNCS)
1076
1077 # This is still experimental (20080329), but should ultimately be moved to
1078 # the script-block --with-normal, etc.
1079 CF_WITH_PTHREAD
1080
1081 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1082 AC_ARG_ENABLE(pthreads-eintr,
1083     [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1084     [use_pthreads_eintr=$enableval],
1085     [use_pthreads_eintr=no])
1086 AC_MSG_RESULT($use_pthreads_eintr)
1087 if test $use_pthreads_eintr = yes ; then
1088     AC_DEFINE(USE_PTHREADS_EINTR)
1089 fi
1090
1091 AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1092 AC_ARG_ENABLE(weak-symbols,
1093     [  --enable-weak-symbols   enable weak-symbols for pthreads],
1094     [use_weak_symbols=$enableval],
1095     [use_weak_symbols=no])
1096 AC_MSG_RESULT($use_weak_symbols)
1097 if test "$use_weak_symbols" = yes ; then
1098     CF_WEAK_SYMBOLS
1099 else
1100     cf_cv_weak_symbols=no
1101 fi
1102
1103 if test $cf_cv_weak_symbols = yes ; then
1104     AC_DEFINE(USE_WEAK_SYMBOLS)
1105 fi
1106
1107 PTHREAD=
1108 if test "$with_pthread" = "yes" ; then
1109     AC_DEFINE(USE_PTHREADS)
1110     enable_reentrant=yes
1111     if test $cf_cv_weak_symbols = yes ; then
1112         PTHREAD=-lpthread
1113     fi
1114 fi
1115 AC_SUBST(PTHREAD)
1116
1117 # Reentrant code has to be opaque; there's little advantage to making ncurses
1118 # opaque outside of that, so there is no --enable-opaque option.  We can use
1119 # this option without --with-pthreads, but this will be always set for
1120 # pthreads.
1121 AC_MSG_CHECKING(if you want experimental reentrant code)
1122 AC_ARG_ENABLE(reentrant,
1123         [  --enable-reentrant      compile with experimental reentrant code],
1124         [with_reentrant=$enableval],
1125         [with_reentrant=no])
1126 AC_MSG_RESULT($with_reentrant)
1127 if test "$with_reentrant" = yes ; then
1128         cf_cv_enable_reentrant=1
1129         cf_cv_enable_opaque="NCURSES_INTERNALS"
1130         NCURSES_OPAQUE=1
1131         NCURSES_SIZE_T=int
1132         if test $cf_cv_weak_symbols = yes ; then
1133                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1134         else
1135                 LIB_SUFFIX="t${LIB_SUFFIX}"
1136         fi
1137         AC_DEFINE(USE_REENTRANT)
1138         CF_NCURSES_ABI_6
1139 else
1140         cf_cv_enable_reentrant=0
1141         cf_cv_enable_opaque="NCURSES_OPAQUE"
1142         NCURSES_OPAQUE=0
1143         NCURSES_SIZE_T=short
1144 fi
1145 AC_SUBST(cf_cv_enable_reentrant)
1146 AC_SUBST(cf_cv_enable_opaque)
1147 AC_SUBST(NCURSES_OPAQUE)
1148 AC_SUBST(NCURSES_SIZE_T)
1149
1150 ### Allow using a different wrap-prefix
1151 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1152         AC_MSG_CHECKING(for prefix used to wrap public variables)
1153         AC_ARG_WITH(wrap-prefix,
1154                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1155                 [NCURSES_WRAP_PREFIX=$withval],
1156                 [NCURSES_WRAP_PREFIX=_nc_])
1157         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1158 else
1159         NCURSES_WRAP_PREFIX=_nc_
1160 fi
1161 AC_SUBST(NCURSES_WRAP_PREFIX)
1162 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX")
1163
1164 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1165 AC_ARG_ENABLE(safe-sprintf,
1166         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1167         [with_safe_sprintf=$enableval],
1168         [with_safe_sprintf=no])
1169 AC_MSG_RESULT($with_safe_sprintf)
1170 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1171
1172 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1173 # when hashmap is used scroll hints are useless
1174 if test "$with_hashmap" = no ; then
1175 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1176 AC_ARG_ENABLE(scroll-hints,
1177         [  --disable-scroll-hints  compile without scroll-hints code],
1178         [with_scroll_hints=$enableval],
1179         [with_scroll_hints=yes])
1180 AC_MSG_RESULT($with_scroll_hints)
1181 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1182 fi
1183
1184 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1185 AC_ARG_ENABLE(wgetch-events,
1186         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1187         [with_wgetch_events=$enableval],
1188         [with_wgetch_events=no])
1189 AC_MSG_RESULT($with_wgetch_events)
1190 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1191
1192 ###############################################################################
1193 CF_HELP_MESSAGE(Testing/development Options:)
1194
1195 ###     use option --disable-echo to suppress full display compiling commands
1196 AC_MSG_CHECKING(if you want to display full commands during build)
1197 AC_ARG_ENABLE(echo,
1198         [  --enable-echo           build: display "compiling" commands (default)],
1199         [with_echo=$enableval],
1200         [with_echo=yes])
1201 if test "$with_echo" = yes; then
1202         ECHO_LINK=
1203 else
1204         ECHO_LINK='@ echo linking $@ ... ;'
1205         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1206         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1207 fi
1208 AC_MSG_RESULT($with_echo)
1209 AC_SUBST(ECHO_LINK)
1210
1211 ###     use option --enable-warnings to turn on all gcc warnings
1212 AC_MSG_CHECKING(if you want to see compiler warnings)
1213 AC_ARG_ENABLE(warnings,
1214         [  --enable-warnings       build: turn on GCC compiler warnings],
1215         [with_warnings=$enableval])
1216 AC_MSG_RESULT($with_warnings)
1217
1218 if test "x$with_warnings" = "xyes"; then
1219         ADAFLAGS="$ADAFLAGS -gnatg"
1220         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1221         if test "$cf_with_cxx" = yes ; then
1222                 CF_GXX_WARNINGS(Wno-unused)
1223         fi
1224 fi
1225 CF_GCC_ATTRIBUTES
1226
1227 ###     use option --enable-assertions to turn on generation of assertion code
1228 AC_MSG_CHECKING(if you want to enable runtime assertions)
1229 AC_ARG_ENABLE(assertions,
1230         [  --enable-assertions     test: turn on generation of assertion code],
1231         [with_assertions=$enableval],
1232         [with_assertions=no])
1233 AC_MSG_RESULT($with_assertions)
1234 if test -n "$GCC"
1235 then
1236         if test "$with_assertions" = no
1237         then
1238                 AC_DEFINE(NDEBUG)
1239                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1240         else
1241                 ADAFLAGS="$ADAFLAGS -gnata"
1242         fi
1243 fi
1244
1245 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1246 CF_DISABLE_LEAKS
1247 AC_DEFINE(HAVE_NC_ALLOC_H)
1248
1249 ###     use option --enable-expanded to generate certain macros as functions
1250 AC_ARG_ENABLE(expanded,
1251         [  --enable-expanded       test: generate functions for certain macros],
1252         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1253
1254 ###     use option --disable-macros to suppress macros in favor of functions
1255 AC_ARG_ENABLE(macros,
1256         [  --disable-macros        test: use functions rather than macros],
1257         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1258
1259 # Normally we only add trace() to the debug-library.  Allow this to be
1260 # extended to all models of the ncurses library:
1261 cf_all_traces=no
1262 case "$CFLAGS $CPPFLAGS" in
1263 *-DTRACE*)
1264         cf_all_traces=yes
1265         ;;
1266 esac
1267
1268 AC_MSG_CHECKING(whether to add trace feature to all models)
1269 AC_ARG_WITH(trace,
1270 [  --with-trace            test: add trace() function to all models of ncurses],
1271 [cf_with_trace=$withval],
1272 [cf_with_trace=$cf_all_traces])
1273 AC_MSG_RESULT($cf_with_trace)
1274
1275 if test "$cf_with_trace" = yes ; then
1276         LIB_TRACING=all
1277         ADA_TRACE=TRUE
1278         CF_ADD_CFLAGS(-DTRACE)
1279 else
1280         LIB_TRACING=DEBUG
1281         ADA_TRACE=FALSE
1282 fi
1283
1284 AC_SUBST(ADA_TRACE)
1285
1286 ###     Checks for libraries.
1287 case $cf_cv_system_name in #(vi
1288 *mingw32*) #(vi
1289         ;;
1290 *)
1291 AC_CHECK_FUNC(gettimeofday,
1292         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1293
1294 AC_CHECK_LIB(bsd, gettimeofday,
1295         AC_DEFINE(HAVE_GETTIMEOFDAY)
1296         LIBS="$LIBS -lbsd")])dnl CLIX: bzero, select, gettimeofday
1297         ;;
1298 esac
1299
1300 CF_MATH_LIB(MATH_LIB,sin(x))
1301 AC_SUBST(MATH_LIB)
1302
1303 ###     Checks for header files.
1304 AC_STDC_HEADERS
1305 AC_HEADER_DIRENT
1306 AC_HEADER_TIME
1307 CF_REGEX
1308
1309 dnl These are some other potentially nonportable headers.
1310 AC_CHECK_HEADERS( \
1311 fcntl.h \
1312 getopt.h \
1313 limits.h \
1314 locale.h \
1315 poll.h \
1316 sys/bsdtypes.h \
1317 sys/ioctl.h \
1318 sys/param.h \
1319 sys/poll.h \
1320 sys/select.h \
1321 sys/time.h \
1322 sys/times.h \
1323 ttyent.h \
1324 unistd.h \
1325 wctype.h \
1326 )
1327
1328 # check for ISC (this may also define _POSIX_SOURCE)
1329 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1330 if test "$ISC" = yes ; then
1331         AC_CHECK_LIB(cposix,main)
1332         AC_CHECK_LIB(inet,bzero,LIBS="$LIBS -linet")dnl also 'select()'
1333 fi
1334
1335 CF_SYS_TIME_SELECT
1336
1337 ###     checks for compiler characteristics
1338 AC_LANG_C
1339 AC_C_CONST
1340 CF_C_INLINE(NCURSES_INLINE,1200)
1341 CF_SIG_ATOMIC_T
1342
1343 if test $NCURSES_CHTYPE = auto ; then
1344         CF_TYPEOF_CHTYPE
1345 else
1346         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1347 fi
1348 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1349 AC_SUBST(cf_cv_typeof_chtype)
1350
1351 CF_UNSIGNED_LITERALS
1352 cf_cv_1UL="1"
1353 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1354 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1355 AC_SUBST(cf_cv_1UL)
1356
1357 if test $NCURSES_MMASK_T = auto ; then
1358         cf_cv_typeof_mmask_t=long
1359 else
1360         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1361 fi
1362 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1363 AC_SUBST(cf_cv_typeof_mmask_t)
1364
1365 ###     Checks for external-data
1366 CF_ERRNO
1367 CF_LINK_DATAONLY
1368
1369 ###     Checks for library functions.
1370 AC_CHECK_FUNCS( \
1371 getcwd \
1372 getegid \
1373 geteuid \
1374 getttynam \
1375 issetugid \
1376 poll \
1377 remove \
1378 select \
1379 setbuf \
1380 setbuffer \
1381 setvbuf \
1382 sigaction \
1383 sigvec \
1384 strdup \
1385 strstr \
1386 tcgetpgrp \
1387 times \
1388 vsnprintf \
1389 )
1390 if test "$with_getcap" = "yes" ; then
1391         CF_CGETENT
1392 fi
1393
1394 CF_ISASCII
1395 CF_STRUCT_SIGACTION
1396 CF_FUNC_NANOSLEEP
1397 CF_FUNC_TERMIOS
1398 CF_FUNC_VSSCANF
1399 CF_MKSTEMP
1400
1401 # setup for prototype of fallback for vsscanf()
1402 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1403
1404 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1405 if test "$cross_compiling" = yes ; then
1406         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1407 else
1408         AC_FUNC_SETVBUF_REVERSED
1409 fi
1410 AC_TYPE_SIGNAL
1411 CF_TYPE_SIGACTION
1412 CF_SIZECHANGE
1413 CF_FUNC_MEMMOVE
1414 CF_FUNC_POLL
1415 CF_VA_COPY
1416 AC_FUNC_VFORK
1417
1418 # special check for test/ditto.c
1419 CF_FUNC_OPENPTY
1420 if test "$cf_cv_func_openpty" != no ; then
1421     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1422     AC_DEFINE(USE_XTERM_PTY)
1423     if test "$cf_cv_lib_util" = yes ; then
1424         TEST_LIBS="-lutil $TEST_LIBS"
1425     fi
1426 fi
1427 AC_SUBST(TEST_LIBS)
1428
1429 if test "$with_hashed_db" != no ; then
1430         AC_DEFINE(USE_HASHED_DB)
1431         CF_HASHED_DB($with_hashed_db)
1432 fi
1433
1434 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1435 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1436         CF_STRIP_G_OPT(CFLAGS)
1437         CF_STRIP_G_OPT(CXXFLAGS)
1438 fi
1439
1440 # Just in case, check if the C compiler has a bool type.
1441 CF_BOOL_DECL(cf_cv_cc_bool_type)
1442
1443 # Check for C++ compiler characteristics (and ensure that it's there!)
1444 if test -n "$CXX" ; then
1445         AC_LANG_CPLUSPLUS
1446         CF_STDCPP_LIBRARY
1447         CF_PROG_CC_C_O(CXX)
1448
1449         case $GXX_VERSION in
1450         1*|2.[0-6]*)
1451                 cf_cxx_library=yes
1452                 ;;
1453         *-2.7*|2.7*)
1454                 CF_GPP_LIBRARY
1455                 ;;
1456         *)
1457                 cf_cxx_library=no
1458                 ;;
1459         esac
1460
1461         AC_CHECK_HEADERS(iostream typeinfo)
1462
1463     if test x"$ac_cv_header_iostream" = xyes ; then
1464         AC_MSG_CHECKING(if iostream uses std-namespace)
1465         AC_TRY_COMPILE([
1466 #include <iostream>
1467 using std::endl;
1468 using std::cerr;],[
1469 cerr << "testing" << endl;
1470 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1471         AC_MSG_RESULT($cf_iostream_namespace)
1472         if test "$cf_iostream_namespace" = yes ; then
1473             AC_DEFINE(IOSTREAM_NAMESPACE)
1474         fi
1475     fi
1476
1477         CF_BOOL_DECL
1478         CF_BOOL_SIZE
1479         CF_ETIP_DEFINES
1480         CF_CPP_PARAM_INIT
1481         CF_CPP_STATIC_CAST
1482
1483         CXX_AR='$(AR)'
1484         CXX_ARFLAGS='$(ARFLAGS)'
1485         case $cf_cv_system_name in #(vi
1486         irix*) #(vi
1487             if test "$GXX" != yes ; then
1488                 CXX_AR='$(CXX)'
1489                 CXX_ARFLAGS='-ar -o'
1490             fi
1491             ;;
1492         sco3.2v5*) #(vi
1493             CXXLDFLAGS="-u main"
1494             ;;
1495         solaris2*)
1496             if test "$GXX" != yes ; then
1497                 CXX_AR='$(CXX)'
1498                 CXX_ARFLAGS='-xar -o'
1499             fi
1500             ;;
1501         esac
1502         AC_SUBST(CXXLDFLAGS)
1503         AC_SUBST(CXX_AR)
1504         AC_SUBST(CXX_ARFLAGS)
1505 else
1506         cf_cxx_library=no
1507         cf_cv_builtin_bool=1
1508
1509         # Just because we are not configuring against C++ right now does not
1510         # mean that a user will not want to use C++.  Some distributors disable
1511         # the C++ portion of this configuration as a shortcut (or just to avoid
1512         # compiling the demo in the c++ directory).  So we need a reasonable
1513         # default for the 'bool' type.
1514         #
1515         # Caveat: since the storage of the bool type is not standardized, it
1516         # may change.
1517
1518         if test "$NCURSES_BOOL" != auto ; then
1519                 cf_cv_type_of_bool=$NCURSES_BOOL
1520                 cf_cv_header_stdbool_h=0
1521         else
1522                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1523                         CF_BOOL_SIZE
1524                 else
1525                         AC_MSG_CHECKING(for fallback type of bool)
1526                         case "$host_cpu" in #(vi
1527                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1528                         *)      cf_cv_type_of_bool=int  ;;
1529                         esac
1530                         AC_MSG_RESULT($cf_cv_type_of_bool)
1531                 fi
1532         fi
1533 fi
1534 AC_SUBST(CXXLIBS)
1535
1536 # If the C compiler did not declare bool, and we did not determine that the C++
1537 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1538 # ncurses library use the same type as C++ bool.  Note that this allows one to
1539 # specify the type of bool in a configure-script option and postpone
1540 # integration with the C++ compiler provided that the types are compatible.
1541 USE_CXX_BOOL=1
1542 if test $cf_cv_cc_bool_type = 1
1543 then
1544         # oops: C has a bool.  Unlikely, but C++ could differ.
1545         USE_CXX_BOOL=0
1546 elif test $cf_cv_builtin_bool = 0
1547 then
1548         # C++ has no bool
1549         USE_CXX_BOOL=0
1550 else
1551         # this is the normal case
1552         USE_CXX_BOOL='defined(__cplusplus)'
1553 fi
1554 AC_SUBST(USE_CXX_BOOL)
1555
1556 CF_HELP_MESSAGE(Ada95 Binding Options:)
1557
1558 dnl If the Ada95 source-tree is present, add that to the build unless it will
1559 dnl not work, or was not requested.
1560 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1561
1562 dnl libtool does not know anything about GNAT, though a change made in 1998
1563 dnl provided for it "someday".  Disable the ada subtree if we are using
1564 dnl libtool -TD 20070714
1565 if test "$cf_with_ada" != "no" ; then
1566     if test "$with_libtool" != "no"; then
1567         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1568         cf_with_ada=no
1569     fi
1570 fi
1571
1572 dnl Check for availability of GNU Ada Translator (GNAT).
1573 dnl At the moment we support no other Ada95 compiler.
1574 if test "$cf_with_ada" != "no" ; then
1575 cf_ada_make=gnatmake
1576 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
1577 if test "$ac_cv_prog_gnat_exists" = no; then
1578    cf_ada_make=
1579 else
1580    CF_GNAT_VERSION
1581    AC_CHECK_PROG(M4_exists, m4, yes, no)
1582    if test "$ac_cv_prog_M4_exists" = no; then
1583       cf_cv_prog_gnat_correct=no
1584       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
1585    fi
1586    if test "$cf_cv_prog_gnat_correct" = yes; then
1587       AC_MSG_CHECKING(if GNAT works)
1588       CF_GNAT_TRY_RUN([procedure conftest;],
1589 [with Text_IO;
1590 with GNAT.OS_Lib;
1591 procedure conftest is
1592 begin
1593    Text_IO.Put ("Hello World");
1594    Text_IO.New_Line;
1595    GNAT.OS_Lib.OS_Exit (0);
1596 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
1597       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
1598    fi
1599 fi
1600 if test "$cf_cv_prog_gnat_correct" = yes; then
1601    ADAFLAGS="-O3 -gnatpn $ADAFLAGS"
1602
1603    AC_MSG_CHECKING(if GNAT pragma Unreferenced works)
1604    CF_GNAT_TRY_LINK([procedure conftest;],
1605 [with Text_IO;
1606 with GNAT.OS_Lib;
1607 procedure conftest is
1608    test : Integer;
1609    pragma Unreferenced (test);
1610 begin
1611    test := 1;
1612    Text_IO.Put ("Hello World");
1613    Text_IO.New_Line;
1614    GNAT.OS_Lib.OS_Exit (0);
1615 end conftest;],[cf_cv_pragma_unreferenced=yes],[cf_cv_pragma_unreferenced=no])
1616    AC_MSG_RESULT($cf_cv_pragma_unreferenced)
1617
1618    # if the pragma is supported, use it (needed in the Trace code).
1619    if test $cf_cv_pragma_unreferenced = yes ; then
1620       PRAGMA_UNREF=TRUE
1621    else
1622       PRAGMA_UNREF=FALSE
1623    fi
1624
1625    AC_ARG_WITH(ada-compiler,
1626         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
1627         [cf_ada_compiler=$withval],
1628         [cf_ada_compiler=gnatmake])
1629
1630    cf_ada_package=terminal_interface
1631
1632    AC_SUBST(cf_ada_make)
1633    AC_SUBST(cf_ada_compiler)
1634    AC_SUBST(cf_ada_package)
1635    AC_SUBST(ADAFLAGS)
1636    AC_SUBST(cf_compile_generics)
1637    AC_SUBST(cf_generic_objects)
1638    AC_SUBST(PRAGMA_UNREF)
1639
1640    CF_WITH_PATH(ada-include,
1641        [  --with-ada-include=DIR  Ada includes are in DIR],
1642        ADA_INCLUDE,
1643        PREFIX/lib/ada/adainclude,
1644        [$]prefix/lib/ada/adainclude)
1645    AC_SUBST(ADA_INCLUDE)
1646
1647    CF_WITH_PATH(ada-objects,
1648        [  --with-ada-objects=DIR  Ada objects are in DIR],
1649        ADA_OBJECTS,
1650        PREFIX/lib/ada/adalib,
1651        [$]prefix/lib/ada/adalib)
1652    AC_SUBST(ADA_OBJECTS)
1653
1654 fi
1655 fi
1656 else
1657    cf_with_ada=no
1658 fi
1659
1660 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1661 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1662 ###
1663 ### ticlib modules may be a separate library, otherwise contained in termlib.
1664 ### termlib modules may be a separate library, otherwise contained in ncurses.
1665 ###
1666 ### The of "+" or " " between the tokens controls the way the script
1667 ### chooses to split module lists into libraries.
1668 ###
1669 ### (see CF_LIB_RULES).
1670 AC_MSG_CHECKING(for library subsets)
1671 LIB_SUBSETS=
1672
1673 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1674         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1675         if test "$with_ticlib" != no ; then
1676                 LIB_SUBSETS="${LIB_SUBSETS} "
1677         else
1678                 LIB_SUBSETS="${LIB_SUBSETS}+"
1679         fi
1680 fi
1681
1682 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1683 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1684
1685 if test "$with_termlib" != no ; then
1686         LIB_SUBSETS="${LIB_SUBSETS} "
1687 else
1688         LIB_SUBSETS="${LIB_SUBSETS}+"
1689 fi
1690
1691 LIB_SUBSETS="${LIB_SUBSETS}base"
1692
1693 # Most term-driver calls are to tinfo, but some like init_pair are to the
1694 # base library (so it resides in base).
1695 if test "$with_term_driver" != no ; then
1696         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1697         case $cf_cv_system_name in #(vi
1698         *mingw32*) #(vi
1699                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1700                 ;;
1701         *) #(vi
1702                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1703                 ;;
1704         esac
1705 fi
1706
1707 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1708 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1709
1710 AC_MSG_RESULT($LIB_SUBSETS)
1711
1712 ### Construct the list of include-directories to be generated
1713 CF_INCLUDE_DIRS
1714 CF_ADA_INCLUDE_DIRS
1715
1716 ### Build up pieces for makefile rules
1717 AC_MSG_CHECKING(default library suffix)
1718 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1719 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1720 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1721
1722 AC_MSG_CHECKING(default library-dependency suffix)
1723 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1724 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1725 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1726
1727 AC_MSG_CHECKING(default object directory)
1728 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1729 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1730 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1731
1732 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1733 if test "$cf_with_cxx" = yes ; then
1734 AC_MSG_CHECKING(c++ library-dependency suffix)
1735 if test "$with_libtool" != "no"; then
1736         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1737 else
1738         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)dnl we normally make a static library
1739 fi
1740 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1741 AC_SUBST(CXX_LIB_SUFFIX)
1742 fi
1743
1744 # do not want -ldl in build except as needed for -lncurses dependency
1745 if test "$with_dlsym" = yes ; then
1746 if test $DFT_LWR_MODEL = shared || \
1747    test $DFT_LWR_MODEL = libtool ; then
1748         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1749 fi
1750 fi
1751 ### Set up low-level terminfo dependencies for makefiles.
1752
1753 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1754 # do not need libdl
1755 TICS_LIST=
1756 if test "$with_dlsym" = yes ; then
1757         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1758 fi
1759
1760 if test "$with_ticlib" != no ; then
1761
1762         if test "$with_ticlib" != yes ; then
1763                 TICS_NAME=$with_ticlib
1764                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1765                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1766                 TICS_LIB_SUFFIX="${with_ticlib}"
1767         else
1768                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1769                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1770                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1771         fi
1772         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1773 else
1774         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1775 fi
1776 AC_SUBST(TICS_ARG_SUFFIX)
1777 AC_SUBST(TICS_DEP_SUFFIX)
1778 AC_SUBST(TICS_LIB_SUFFIX)
1779 AC_SUBST(TICS_ARGS)
1780
1781 if test "$with_termlib" != no ; then
1782
1783         if test "$with_termlib" != yes ; then
1784                 TINFO_NAME=$with_termlib
1785                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1786                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1787                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1788                 TINFO_LIB_SUFFIX="${with_termlib}"
1789         else
1790                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1791                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1792                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1793                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1794         fi
1795
1796         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1797         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1798         if test "$DFT_LWR_MODEL" = "libtool"; then
1799                 TEST_ARGS="${TEST_DEPS}"
1800                 TEST_ARG2="${TEST_DEP2}"
1801                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1802                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1803                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1804         else
1805                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1806                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1807                 TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1808                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1809                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1810         fi
1811 else
1812         # the next lines are needed for linking libtic over libncurses
1813         TINFO_NAME=${LIB_NAME}
1814         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1815         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1816         if test "$with_tic_depends" = yes ; then
1817                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1818         else
1819                 TICS_LIST="$SHLIB_LIST"
1820         fi
1821
1822         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1823 fi
1824
1825 if test "$DFT_LWR_MODEL" = shared ; then
1826         case $cf_cv_system_name in #(vi
1827         cygwin*)
1828                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1829                 TINFO_SUFFIX=.dll
1830                 ;;
1831         esac
1832 fi
1833
1834 AC_SUBST(TINFO_ARG_SUFFIX)
1835 AC_SUBST(TINFO_DEP_SUFFIX)
1836 AC_SUBST(TINFO_LIB_SUFFIX)
1837 AC_SUBST(TINFO_ARGS)
1838
1839 if test "$with_dlsym" = yes ; then
1840         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1841 fi
1842
1843 if test "$DFT_LWR_MODEL" = "libtool"; then
1844     OBJEXT=lo
1845 fi
1846
1847 # needed for Ada95
1848 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1849 AC_SUBST(TINFO_ARGS2)
1850
1851 case $DFT_LWR_MODEL in
1852 normal|debug|profile)
1853         CF_LDFLAGS_STATIC
1854         ;;
1855 esac
1856
1857 AC_MSG_CHECKING(where we will install curses.h)
1858 test "$with_overwrite" = no && \
1859 test "x$includedir" = 'x${prefix}/include' && \
1860         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1861 AC_MSG_RESULT($includedir)
1862
1863 ### Resolve a conflict between normal and wide-curses by forcing applications
1864 ### that will need libutf8 to add it to their configure script.
1865 if test "$with_overwrite" != no ; then
1866 if test "$NCURSES_LIBUTF8" = 1 ; then
1867         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1868         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1869 fi
1870 fi
1871 WITH_OVERWRITE=$with_overwrite
1872
1873 AC_SUBST(WITH_OVERWRITE)
1874 AC_SUBST(TICS_LIST)
1875 AC_SUBST(TINFO_LIST)
1876 AC_SUBST(SHLIB_LIST)
1877
1878 # used to separate tack out of the tree
1879 NCURSES_TREE=
1880 AC_SUBST(NCURSES_TREE)
1881
1882 ### predefined stuff for the test programs
1883 AC_DEFINE(HAVE_SLK_COLOR)
1884
1885 ### Construct the list of subdirectories for which we'll customize makefiles
1886 ### with the appropriate compile-rules.
1887
1888 CF_SRC_MODULES($modules_to_build)
1889
1890 if test "$cf_with_ada" != "no" && test "$cf_cv_prog_gnat_correct" != "no"; then
1891    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1892    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${DFT_ARG_SUFFIX}-config.1:man/MKada_config.in"
1893 fi
1894
1895 CF_DIRS_TO_MAKE
1896
1897 # symbols that differ when compiling Ada95 by itself.
1898 NCURSES_SHLIB2='sh $(top_srcdir)/misc/shlib'
1899 AC_SUBST(NCURSES_SHLIB2)
1900
1901 NCURSES_COPY2='sh $(top_srcdir)/tar-copy.sh'
1902 AC_SUBST(NCURSES_COPY2)
1903
1904 # values to use as strings
1905 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR')
1906
1907 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1908
1909 ### Now that we're done running tests, add the compiler-warnings, if any
1910 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1911
1912 ### If we're building with rpath, try to link non-standard libs that way too.
1913 if test "$DFT_LWR_MODEL" = "shared"; then
1914         CF_DISABLE_RPATH_HACK
1915 fi
1916
1917 ### Define substitutions for header files to avoid name-pollution
1918 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1919 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1920 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1921
1922 ################################################################################
1923 test "$use_database" = yes && \
1924 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1925
1926 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1927 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${DFT_ARG_SUFFIX}${cf_cv_abi_version}-config.1:man/MKncu_config.in"
1928
1929 if test x"$enable_pc_files" = xyes ; then \
1930 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1931 MAKE_PC_FILES=
1932 else
1933 MAKE_PC_FILES="#"
1934 fi
1935 AC_SUBST(MAKE_PC_FILES)
1936 AC_SUBST(cross_compiling)
1937
1938 AC_OUTPUT( \
1939         include/MKterm.h.awk \
1940         include/curses.head:include/curses.h.in \
1941         include/ncurses_dll.h \
1942         include/termcap.h \
1943         include/unctrl.h \
1944         $SUB_MAKEFILES \
1945         Makefile,[
1946 CF_PRG_RULES([$srcdir/test/mk-test.awk ECHO_LINK="$ECHO_LINK"], test)
1947 CF_LIB_RULES($SRC_SUBDIRS)
1948 ],[
1949 ### Special initialization commands, used to pass information from the
1950 ### configuration-run into config.status
1951
1952 AWK="$AWK"
1953 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1954 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1955 ECHO_LINK="$ECHO_LINK"
1956 LDCONFIG="$LDCONFIG"
1957 LIBTOOL_VERSION="$LIBTOOL_VERSION"
1958 LIB_NAME="$LIB_NAME"
1959 LIB_SUBSETS="$LIB_SUBSETS"
1960 LIB_SUFFIX="$LIB_SUFFIX"
1961 LIB_TRACING="$LIB_TRACING"
1962 MAKE_TERMINFO="$MAKE_TERMINFO"
1963 NCURSES_MAJOR="$NCURSES_MAJOR"
1964 NCURSES_MINOR="$NCURSES_MINOR"
1965 NCURSES_OSPEED="$NCURSES_OSPEED"
1966 NCURSES_PATCH="$NCURSES_PATCH"
1967 SRC_SUBDIRS="$SRC_SUBDIRS"
1968 TERMINFO="$TERMINFO"
1969 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1970 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1971 TICS_NAME="$TICS_NAME"
1972 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1973 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1974 TINFO_NAME="$TINFO_NAME"
1975 TINFO_SUFFIX="$TINFO_SUFFIX"
1976 WITH_CURSES_H="$with_curses_h"
1977 WITH_ECHO="$with_echo"
1978 WITH_OVERWRITE="$with_overwrite"
1979 cf_LIST_MODELS="$cf_list_models"
1980 cf_cv_abi_version="$cf_cv_abi_version"
1981 cf_cv_do_relink="$cf_cv_do_relink"
1982 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1983 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1984 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1985 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1986 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1987 cf_cv_rel_version="$cf_cv_rel_version"
1988 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1989 cf_cv_shared_soname='$cf_cv_shared_soname'
1990 cf_cv_shlib_version="$cf_cv_shlib_version"
1991 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1992 cf_cv_system_name="$cf_cv_system_name"
1993 cf_with_cxx_binding="$cf_with_cxx_binding"
1994 cf_with_manpages="$cf_with_manpages"
1995 host="$host"
1996 target="$target"
1997
1998 ],cat)dnl
1999 ${MAKE-make} preinstall