ncurses 5.7 - patch 20090105
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2008,2009 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: configure.in,v 1.463 2009/01/06 01:40:09 tom Exp $
32 dnl Process this file with autoconf to produce a configure script.
33 dnl
34 dnl See http://invisible-island.net/autoconf/ for additional information.
35 dnl
36 dnl ---------------------------------------------------------------------------
37 AC_PREREQ(2.13.20020210)
38 AC_REVISION($Revision: 1.463 $)
39 AC_INIT(ncurses/base/lib_initscr.c)
40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
41
42 CF_TOP_BUILDDIR
43 CF_SUBST_NCURSES_VERSION
44
45 CF_WITH_REL_VERSION(NCURSES)
46 CF_WITH_ABI_VERSION
47
48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
49 AC_ARG_WITH(system-type,
50 [  --with-system-type=XXX  test: override derived host system-type],
51 [AC_MSG_WARN(overriding system type to $withval)
52  cf_cv_system_name=$withval])
53
54 ###     Save the given $CFLAGS to allow user-override.
55 cf_user_CFLAGS="$CFLAGS"
56
57 ###     Default install-location
58 CF_CFG_DEFAULTS
59
60 ###     Checks for programs.
61 AC_PROG_CC
62 CF_GCC_VERSION
63
64 AC_PROG_CPP
65 AC_PROG_GCC_TRADITIONAL
66 CF_PROG_CC_C_O(CC)
67 AC_ISC_POSIX
68 CF_ANSI_CC_REQD
69 CF_PROG_EXT
70 CF_PROG_LDCONFIG
71
72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
73 dnl                             configure script by not letting us test if C++
74 dnl                             is present, making this option necessary.
75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
76 AC_ARG_WITH(cxx,
77         [  --without-cxx           do not adjust ncurses bool to match C++],
78         [cf_with_cxx=$withval],
79         [cf_with_cxx=yes])
80 AC_MSG_RESULT($cf_with_cxx)
81 if test "X$cf_with_cxx" = Xno ; then
82         CXX=""
83         GXX=""
84 else
85         # with autoconf 2.13, we can change the error to a warning:
86         pushdef([AC_MSG_ERROR],
87                 [AC_MSG_RESULT(no)
88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
90         AC_PROG_CXX
91         popdef([AC_MSG_ERROR])dnl
92         # autoconf 2.5x removed the error - by hardcoding it to g++.
93         if test "$CXX" = "g++" ; then
94                 AC_PATH_PROG(CXX,g++)
95         fi
96         if test "$CXX" = "g++" ; then
97                 AC_MSG_WARN(ignoring hardcoded g++)
98                 cf_with_cxx=no; CXX=""; GXX="";
99         fi
100 fi
101
102 CF_GXX_VERSION
103 case $GXX_VERSION in
104 1*|2.[[0-6]]*)
105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
106         # cf_cxx_library=no
107         AC_MSG_WARN(templates do not work)
108         ;;
109 esac
110
111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
112 AC_ARG_WITH(cxx-binding,
113         [  --without-cxx-binding   do not build C++ binding and demo],
114         [cf_with_cxx_binding=$withval],
115         [cf_with_cxx_binding=$cf_with_cxx])
116 AC_MSG_RESULT($cf_with_cxx_binding)
117
118 AC_MSG_CHECKING(if you want to build with Ada95)
119 AC_ARG_WITH(ada,
120         [  --without-ada           suppress check for Ada95, don't build demo],
121         [cf_with_ada=$withval],
122         [cf_with_ada=yes])
123 AC_MSG_RESULT($cf_with_ada)
124
125 AC_MSG_CHECKING(if you want to install manpages)
126 AC_ARG_WITH(manpages,
127         [  --without-manpages      suppress install of manpages],
128         [cf_with_manpages=$withval],
129         [cf_with_manpages=yes])
130 AC_MSG_RESULT($cf_with_manpages)
131
132 AC_MSG_CHECKING(if you want to build programs such as tic)
133 AC_ARG_WITH(progs,
134         [  --without-progs         suppress build with programs (e.g., tic)],
135         [cf_with_progs=$withval],
136         [cf_with_progs=yes])
137 AC_MSG_RESULT($cf_with_progs)
138
139 AC_MSG_CHECKING(if you wish to install curses.h)
140 AC_ARG_WITH(curses-h,
141         [  --without-curses-h      install curses.h as ncurses.h only],
142         [with_curses_h=$withval],
143         [with_curses_h=yes])
144 AC_MSG_RESULT($with_curses_h)
145
146 modules_to_build="ncurses"
147 if test "X$cf_with_progs" != Xno ; then
148 modules_to_build="$modules_to_build progs tack"
149 fi
150 modules_to_build="$modules_to_build panel menu form"
151
152 AC_ARG_PROGRAM
153
154 CF_PROG_AWK
155 CF_PROG_EGREP
156 CF_PROG_INSTALL
157 CF_PROG_LINT
158 AC_PROG_LN_S
159
160 AC_SYS_LONG_FILE_NAMES
161
162 # if we find pkg-config, check if we should install the ".pc" files.
163 CF_PKG_CONFIG
164
165 if test "$PKG_CONFIG" != no ; then
166         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
167
168         # Leave this as something that can be overridden in the environment.
169         if test -z "$PKG_CONFIG_LIBDIR" ; then
170                 PKG_CONFIG_LIBDIR=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`/lib/pkgconfig
171         fi
172
173         if test -d "$PKG_CONFIG_LIBDIR" ; then
174                 AC_ARG_ENABLE(pc-files,
175                         [  --enable-pc-files       generate and install .pc files for pkg-config],
176                         [enable_pc_files=$enableval],
177                         [enable_pc_files=no])
178                 AC_MSG_RESULT($enable_pc_files)
179         else
180                 AC_MSG_RESULT(no)
181                 AC_MSG_WARN(did not find library $PKG_CONFIG_LIBDIR)
182                 enable_pc_files=no
183         fi
184 fi
185 AC_SUBST(PKG_CONFIG_LIBDIR)
186
187 AC_MSG_CHECKING(if we should assume mixed-case filenames)
188 AC_ARG_ENABLE(mixed-case,
189         [  --enable-mixed-case     tic should assume mixed-case filenames],
190         [enable_mixedcase=$enableval],
191         [enable_mixedcase=auto])
192 AC_MSG_RESULT($enable_mixedcase)
193 if test "$enable_mixedcase" = "auto" ; then
194     CF_MIXEDCASE_FILENAMES
195 else
196     cf_cv_mixedcase=$enable_mixedcase
197     if test "$enable_mixedcase" = "yes" ; then
198         AC_DEFINE(MIXEDCASE_FILENAMES)
199     fi
200 fi
201
202 # do this after mixed-case option (tags/TAGS is not as important as tic).
203 AC_PROG_MAKE_SET
204 CF_MAKE_TAGS
205 CF_MAKEFLAGS
206
207 dnl These are standard among *NIX systems, but not when cross-compiling
208 AC_CHECK_TOOL(RANLIB, ranlib, ':')
209 AC_CHECK_TOOL(LD, ld, ld)
210 AC_CHECK_TOOL(AR, ar, ar)
211 CF_AR_FLAGS
212
213 dnl Special option for use by system-builders: the install-prefix is used to
214 dnl adjust the location into which the actual install is done, so that an
215 dnl archive can be built without modifying the host system's configuration.
216 AC_MSG_CHECKING(if you have specified an install-prefix)
217 AC_ARG_WITH(install-prefix,
218         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
219         [case "$withval" in #(vi
220         yes|no) #(vi
221                 ;;
222         *)      DESTDIR="$withval"
223                 ;;
224         esac])
225 AC_MSG_RESULT($DESTDIR)
226 AC_SUBST(DESTDIR)
227
228 ###############################################################################
229 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
230 # If we're cross-compiling, allow the user to override the tools and their
231 # options.  The configure script is oriented toward identifying the host
232 # compiler, etc., but we need a build compiler to generate parts of the source.
233 CF_BUILD_CC
234
235 ###############################################################################
236 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
237
238 ### Options to allow the user to specify the set of libraries which are used.
239 ### Use "--without-normal --with-shared" to allow the default model to be
240 ### shared, for example.
241 cf_list_models=""
242 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
243
244 CF_WITH_LIBTOOL
245 if test "$with_libtool" != "no" ; then
246
247 cf_list_models="$cf_list_models libtool"
248
249 else
250
251 AC_MSG_CHECKING(if you want to build shared libraries)
252 AC_ARG_WITH(shared,
253         [  --with-shared           generate shared-libraries],
254         [with_shared=$withval],
255         [with_shared=no])
256 AC_MSG_RESULT($with_shared)
257 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
258
259 AC_MSG_CHECKING(if you want to build static libraries)
260 AC_ARG_WITH(normal,
261         [  --with-normal           generate normal-libraries (default)],
262         [with_normal=$withval],
263         [with_normal=yes])
264 AC_MSG_RESULT($with_normal)
265 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
266
267 AC_MSG_CHECKING(if you want to build debug libraries)
268 AC_ARG_WITH(debug,
269         [  --with-debug            generate debug-libraries (default)],
270         [with_debug=$withval],
271         [with_debug=yes])
272 AC_MSG_RESULT($with_debug)
273 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
274
275 AC_MSG_CHECKING(if you want to build profiling libraries)
276 AC_ARG_WITH(profile,
277         [  --with-profile          generate profile-libraries],
278         [with_profile=$withval],
279         [with_profile=no])
280 AC_MSG_RESULT($with_profile)
281 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
282
283 fi
284
285 ###############################################################################
286
287 AC_MSG_CHECKING(for specified models)
288 test -z "$cf_list_models" && cf_list_models=normal
289 dnl If we use libtool to generate libraries, then it must be the only
290 dnl specified model.
291 test "$with_libtool" != "no" && cf_list_models=libtool
292 AC_MSG_RESULT($cf_list_models)
293
294 ### Use the first model as the default, and save its suffix for use in building
295 ### up test-applications.
296 AC_MSG_CHECKING(for default model)
297 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
298 AC_MSG_RESULT($DFT_LWR_MODEL)
299
300 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
301
302 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
303 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
304
305 TICS_NAME=tic
306 AC_SUBST(TICS_NAME)
307
308 TINFO_NAME=tinfo
309 AC_SUBST(TINFO_NAME)
310
311 LIB_NAME=ncurses
312 AC_SUBST(LIB_NAME)
313
314 LIB_DIR=../lib
315 LIB_2ND=../../lib
316
317 CF_LIB_PREFIX(cf_prefix)
318 LIB_PREFIX=$cf_prefix
319 AC_SUBST(LIB_PREFIX)
320
321 LIB_SUFFIX=
322 AC_SUBST(LIB_SUFFIX)
323
324 ###############################################################################
325
326 AC_MSG_CHECKING(if you want to build a separate terminfo library)
327 AC_ARG_WITH(termlib,
328         [  --with-termlib          generate separate terminfo library],
329         [with_termlib=$withval],
330         [with_termlib=no])
331 AC_MSG_RESULT($with_termlib)
332
333 AC_MSG_CHECKING(if you want to build a separate tic library)
334 AC_ARG_WITH(ticlib,
335         [  --with-ticlib           generate separate tic library],
336         [with_ticlib=$withval],
337         [with_ticlib=no])
338 AC_MSG_RESULT($with_ticlib)
339
340 ### Checks for special libraries, must be done up-front.
341 SHLIB_LIST=""
342 CF_WITH_GPM
343 if test "$with_gpm" != no ; then
344         AC_MSG_CHECKING(if you want to load GPM dynamically)
345         AC_ARG_WITH(dlsym,
346                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
347                 [with_dlsym=$withval],
348                 [with_dlsym=yes])
349         AC_MSG_RESULT($with_dlsym)
350         if test "$with_dlsym" = yes ; then
351                 CF_FUNC_DLSYM
352                 if test "$with_gpm" != yes ; then
353                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
354                         cf_cv_gpm_soname="$with_gpm"
355                 else
356                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
357                 fi
358                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
359                 SHLIB_LIST="-ldl $SHLIB_LIST"
360         else
361                 SHLIB_LIST="-lgpm $SHLIB_LIST"
362         fi
363         AC_DEFINE(HAVE_LIBGPM)
364         CF_CHECK_GPM_WGETCH
365 fi
366
367 CF_WITH_SYSMOUSE
368
369 dnl Not all ports of gcc support the -g option
370
371 if test X"$CC_G_OPT" = X"" ; then
372         CC_G_OPT='-g'
373         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
374 fi
375 AC_SUBST(CC_G_OPT)
376
377 if test X"$CXX_G_OPT" = X"" ; then
378         CXX_G_OPT='-g'
379         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
380 fi
381 AC_SUBST(CXX_G_OPT)
382
383 AC_MSG_CHECKING(for default loader flags)
384 case $DFT_LWR_MODEL in
385 libtool) LD_MODEL=''   ;;
386 normal)  LD_MODEL=''   ;;
387 debug)   LD_MODEL=$CC_G_OPT ;;
388 profile) LD_MODEL='-pg';;
389 shared)  LD_MODEL=''   ;;
390 esac
391 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
392 AC_MSG_RESULT($LD_MODEL)
393
394 case $DFT_LWR_MODEL in
395 shared)
396 CF_ENABLE_RPATH
397 AC_MSG_CHECKING(if shared libraries should be relinked during install)
398 AC_ARG_ENABLE(relink,
399 [  --disable-relink        relink shared libraries during install],
400 [cf_cv_do_relink=$enableval],
401 [cf_cv_do_relink=yes])
402 AC_MSG_RESULT($cf_cv_do_relink)
403         ;;
404 esac
405
406 CF_SHARED_OPTS
407 if test "$CC_SHARED_OPTS" = "unknown"; then
408         for model in $cf_list_models; do
409                 if test "$model" = "shared"; then
410                         AC_ERROR(Shared libraries are not supported in this version)
411                 fi
412         done
413 fi
414
415 ###############################################################################
416 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
417
418 ###     use option --disable-overwrite to leave out the link to -lcurses
419 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
420 AC_ARG_ENABLE(overwrite,
421         [  --disable-overwrite     leave out the link to -lcurses],
422         [with_overwrite=$enableval],
423         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
424 AC_MSG_RESULT($with_overwrite)
425
426 AC_MSG_CHECKING(if external terminfo-database is used)
427 AC_ARG_ENABLE(database,
428         [  --disable-database      do not use terminfo, only fallbacks/termcap],
429         [use_database=$enableval],
430         [use_database=yes])
431 AC_MSG_RESULT($use_database)
432
433 case $host_os in #(vi
434 os2*) #(vi
435         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
436         ;;
437 *) #(vi
438         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
439         ;;
440 esac
441 AC_SUBST(TERMINFO_SRC)
442
443 CF_PATHSEP
444 if test "$use_database" != no ; then
445         AC_DEFINE(USE_DATABASE)
446
447         AC_MSG_CHECKING(which terminfo source-file will be installed)
448         AC_ARG_ENABLE(database,
449                 [  --with-database=XXX     specify terminfo source to install],
450                 [TERMINFO_SRC=$withval])
451         AC_MSG_RESULT($TERMINFO_SRC)
452
453         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
454         AC_ARG_WITH(hashed-db,
455                 [  --with-hashed-db        specify hashed-database library],,
456                 [with_hashed_db=no])
457         AC_MSG_RESULT($with_hashed_db)
458 else
459         with_hashed_db=no
460 fi
461
462 AC_MSG_CHECKING(for list of fallback descriptions)
463 AC_ARG_WITH(fallbacks,
464         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
465         [with_fallback=$withval],
466         [with_fallback=])
467 AC_MSG_RESULT($with_fallback)
468 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
469 AC_SUBST(FALLBACK_LIST)
470
471 AC_MSG_CHECKING(if you want modern xterm or antique)
472 AC_ARG_WITH(xterm-new,
473         [  --without-xterm-new     specify if xterm terminfo should be old version],
474         [with_xterm_new=$withval],
475         [with_xterm_new=yes])
476 case $with_xterm_new in
477 no)     with_xterm_new=xterm-old;;
478 *)      with_xterm_new=xterm-new;;
479 esac
480 AC_MSG_RESULT($with_xterm_new)
481 WHICH_XTERM=$with_xterm_new
482 AC_SUBST(WHICH_XTERM)
483
484 MAKE_TERMINFO=
485 if test "$use_database" = no ; then
486         TERMINFO="${datadir}/terminfo"
487         MAKE_TERMINFO="#"
488 else
489
490 AC_MSG_CHECKING(for list of terminfo directories)
491 CF_WITH_PATHLIST(terminfo-dirs,
492         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
493         TERMINFO_DIRS,
494         DATADIR/terminfo,
495         ${datadir}/terminfo)
496 AC_MSG_RESULT($TERMINFO_DIRS)
497 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
498
499 AC_MSG_CHECKING(for default terminfo directory)
500 CF_WITH_PATH(default-terminfo-dir,
501         [  --with-default-terminfo-dir=DIR default terminfo directory],
502         TERMINFO,
503         DATADIR/terminfo,
504         ${datadir}/terminfo)
505 AC_MSG_RESULT($TERMINFO)
506 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
507
508 fi
509
510 AC_SUBST(TERMINFO)
511 AC_SUBST(MAKE_TERMINFO)
512
513 ###     use option --disable-big-core to make tic run on small machines
514 ###     We need 4Mb, check if we can allocate 50% more than that.
515 AC_MSG_CHECKING(if big-core option selected)
516 AC_ARG_ENABLE(big-core,
517         [  --disable-big-core      assume machine has little memory],
518         [with_big_core=$enableval],
519         [AC_TRY_RUN([
520 #include <stdlib.h>
521 #include <string.h>
522 int main() {
523         unsigned long n = 6000000L;
524         char *s = malloc(n);
525         if (s != 0)
526                 s[0] = s[n-1] = 0;
527         ${cf_cv_main_return:-return}(s == 0);
528 }],
529         [with_big_core=yes],
530         [with_big_core=no],
531         [with_big_core=no])])
532 AC_MSG_RESULT($with_big_core)
533 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
534
535 ### ISO C only guarantees 512-char strings, we have tables which load faster
536 ### when constructed using "big" strings.  More than the C compiler, the awk
537 ### program is a limit on most vendor UNIX systems.  Check that we can build.
538 AC_MSG_CHECKING(if big-strings option selected)
539 AC_ARG_ENABLE(big-strings,
540         [  --disable-big-strings   assume compiler has only standard-size strings],
541         [with_big_strings=$enableval],
542         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
543 AC_MSG_RESULT($with_big_strings)
544
545 USE_BIG_STRINGS=0
546 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
547 AC_SUBST(USE_BIG_STRINGS)
548
549 ###     use option --enable-termcap to compile in the termcap fallback support
550 AC_MSG_CHECKING(if you want termcap-fallback support)
551 AC_ARG_ENABLE(termcap,
552         [  --enable-termcap        compile in termcap fallback support],
553         [with_termcap=$enableval],
554         [with_termcap=no])
555 AC_MSG_RESULT($with_termcap)
556
557 if test "$with_termcap" != "yes" ; then
558         if test "$use_database" = no ; then
559                 if test -z "$with_fallback" ; then
560                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
561                 fi
562         fi
563         AC_DEFINE(PURE_TERMINFO)
564 else
565
566 if test "$with_ticlib" != no ; then
567         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
568 fi
569
570 AC_DEFINE(USE_TERMCAP)
571 AC_MSG_CHECKING(for list of termcap files)
572 CF_WITH_PATHLIST(termpath,
573         [  --with-termpath=XXX     specify list of termcap files],
574         TERMPATH,
575         /etc/termcap:/usr/share/misc/termcap)
576 AC_MSG_RESULT($TERMPATH)
577 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
578
579 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
580 AC_MSG_CHECKING(if fast termcap-loader is needed)
581 AC_ARG_ENABLE(getcap,
582         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
583         [with_getcap=$enableval],
584         [with_getcap=no])
585 AC_MSG_RESULT($with_getcap)
586 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
587
588 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
589 AC_ARG_ENABLE(getcap-cache,
590         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
591         [with_getcap_cache=$enableval],
592         [with_getcap_cache=no])
593 AC_MSG_RESULT($with_getcap_cache)
594 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
595
596 fi
597
598 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
599 AC_MSG_CHECKING(if ~/.terminfo is wanted)
600 AC_ARG_ENABLE(home-terminfo,
601         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
602         [with_home_terminfo=$enableval],
603         [with_home_terminfo=yes])
604 AC_MSG_RESULT($with_home_terminfo)
605 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
606
607 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
608 AC_ARG_ENABLE(root-environ,
609         [  --disable-root-environ  restrict environment when running as root],
610         [with_root_environ=$enableval],
611         [with_root_environ=yes])
612 AC_MSG_RESULT($with_root_environ)
613 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
614
615 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
616 ###   to reduce storage requirements for the terminfo database.
617 CF_LINK_FUNCS
618
619 with_links=no
620 with_symlinks=no
621
622 # soft links (symbolic links) are useful for some systems where hard links do
623 # not work, or to make it simpler to copy terminfo trees around.
624 if test "$ac_cv_func_symlink" = yes ; then
625     AC_MSG_CHECKING(if tic should use symbolic links)
626     AC_ARG_ENABLE(symlinks,
627         [  --enable-symlinks       make tic use symbolic links not hard links],
628         [with_symlinks=$enableval],
629         [with_symlinks=no])
630     AC_MSG_RESULT($with_symlinks)
631 fi
632
633 # If we have hard links and did not choose to use soft links instead, there is
634 # no reason to make this choice optional - use the hard links.
635 if test "$with_symlinks" = no ; then
636     AC_MSG_CHECKING(if tic should use hard links)
637     if test "$ac_cv_func_link" = yes ; then
638         with_links=yes
639     else
640         with_links=no
641     fi
642     AC_MSG_RESULT($with_links)
643 fi
644
645 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
646 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
647
648 ###   use option --enable-broken-linker to force on use of broken-linker support
649 AC_MSG_CHECKING(if you want broken-linker support code)
650 AC_ARG_ENABLE(broken_linker,
651         [  --enable-broken_linker  compile with broken-linker support code],
652         [with_broken_linker=$enableval],
653         [with_broken_linker=${BROKEN_LINKER-no}])
654 AC_MSG_RESULT($with_broken_linker)
655
656 BROKEN_LINKER=0
657 if test "$with_broken_linker" = yes ; then
658         AC_DEFINE(BROKEN_LINKER)
659         BROKEN_LINKER=1
660 elif test "$DFT_LWR_MODEL" = shared ; then
661         case $cf_cv_system_name in #(vi
662         cygwin*)
663                 AC_DEFINE(BROKEN_LINKER)
664                 BROKEN_LINKER=1
665                 CF_VERBOSE(cygwin linker is broken anyway)
666                 ;;
667         esac
668 fi
669 AC_SUBST(BROKEN_LINKER)
670
671 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
672 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
673 AC_ARG_ENABLE(bsdpad,
674         [  --enable-bsdpad         recognize BSD-style prefix padding],
675         [with_bsdpad=$enableval],
676         [with_bsdpad=no])
677 AC_MSG_RESULT($with_bsdpad)
678 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
679
680 ###   use option --enable-widec to turn on use of wide-character support
681 NCURSES_CH_T=chtype
682 NCURSES_LIBUTF8=0
683
684 NEED_WCHAR_H=0
685 NCURSES_MBSTATE_T=0
686 NCURSES_WCHAR_T=0
687 NCURSES_WINT_T=0
688
689 # Check to define _XOPEN_SOURCE "automatically"
690 CF_XOPEN_SOURCE
691
692 # Work around breakage on OS X
693 CF_SIGWINCH
694
695 # Checks for CODESET support.
696 AM_LANGINFO_CODESET
697
698 # use these variables to work around a defect in gcc's fixincludes.
699 NCURSES_OK_WCHAR_T=
700 NCURSES_OK_WINT_T=
701
702 AC_MSG_CHECKING(if you want wide-character code)
703 AC_ARG_ENABLE(widec,
704         [  --enable-widec          compile with wide-char/UTF-8 code],
705         [with_widec=$enableval],
706         [with_widec=no])
707 AC_MSG_RESULT($with_widec)
708 if test "$with_widec" = yes ; then
709         LIB_SUFFIX="w${LIB_SUFFIX}"
710         AC_DEFINE(USE_WIDEC_SUPPORT)
711         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
712         # with_overwrite=no
713         NCURSES_CH_T=cchar_t
714         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
715         if test "$ac_cv_func_putwc" != yes ; then
716                 CF_UTF8_LIB
717                 if test "$cf_cv_utf8_lib" != no ; then
718                         NCURSES_LIBUTF8=1
719                 fi
720         fi
721         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
722         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
723         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
724
725         if test "$NCURSES_MBSTATE_T" != 0; then
726                 AC_DEFINE(NEED_MBSTATE_T_DEF)
727         fi
728 fi
729 AC_SUBST(NCURSES_CH_T)
730 AC_SUBST(NCURSES_LIBUTF8)
731
732 AC_SUBST(NEED_WCHAR_H)
733 AC_SUBST(NCURSES_MBSTATE_T)
734 AC_SUBST(NCURSES_WCHAR_T)
735 AC_SUBST(NCURSES_WINT_T)
736
737 AC_SUBST(NCURSES_OK_WCHAR_T)
738 AC_SUBST(NCURSES_OK_WINT_T)
739
740 ###   use option --disable-lp64 to allow long chtype
741 case $cf_cv_abi_version in
742 [[345]]*)
743         default_with_lp64=no
744         ;;
745 *)
746         default_with_lp64=yes
747         ;;
748 esac
749
750 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
751 AC_ARG_ENABLE(lp64,
752         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
753         [with_lp64=$enableval],
754         [with_lp64=$default_with_lp64])
755 AC_MSG_RESULT($with_lp64)
756
757 if test "$with_lp64" = yes ; then
758         cf_cv_enable_lp64=1
759 else
760         cf_cv_enable_lp64=0
761 fi
762 AC_SUBST(cf_cv_enable_lp64)
763
764 CF_LARGEFILE
765
766 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
767 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
768 AC_ARG_ENABLE(tparm-varargs,
769         [  --disable-tparm-varargs compile tparm() without varargs interface],
770         [with_tparm_varargs=$enableval],
771         [with_tparm_varargs=yes])
772 AC_MSG_RESULT($with_tparm_varargs)
773 NCURSES_TPARM_VARARGS=0
774 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
775 AC_SUBST(NCURSES_TPARM_VARARGS)
776
777 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
778 if test "$with_ticlib" != no ; then
779 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
780 AC_ARG_ENABLE(tic-depends,
781         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
782         [with_tic_depends=$enableval],
783         [with_tic_depends=yes])
784 AC_MSG_RESULT($with_tic_depends)
785 else
786         with_tic_depends=no
787 fi
788
789 ###   use option --with-bool to override bool's type
790 AC_MSG_CHECKING(for type of bool)
791 AC_ARG_WITH(bool,
792         [  --with-bool=TYPE        override fallback type of bool variable],
793         [NCURSES_BOOL="$withval"],
794         [NCURSES_BOOL=auto])
795 AC_MSG_RESULT($NCURSES_BOOL)
796 AC_SUBST(NCURSES_BOOL)
797
798 AC_MSG_CHECKING(for alternate terminal capabilities file)
799 AC_ARG_WITH(caps,
800         [  --with-caps=alt         compile with alternate Caps file],
801         [TERMINFO_CAPS=Caps.$withval],
802         [TERMINFO_CAPS=Caps])
803 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
804 AC_MSG_RESULT($TERMINFO_CAPS)
805 AC_SUBST(TERMINFO_CAPS)
806
807 ###   use option --with-chtype to override chtype's type
808 AC_MSG_CHECKING(for type of chtype)
809 AC_ARG_WITH(chtype,
810         [  --with-chtype=TYPE      override type of chtype],
811         [NCURSES_CHTYPE="$withval"],
812         [NCURSES_CHTYPE=auto])
813 AC_MSG_RESULT($NCURSES_CHTYPE)
814
815 ###   use option --with-ospeed to override ospeed's type
816 AC_MSG_CHECKING(for type of ospeed)
817 AC_ARG_WITH(ospeed,
818         [  --with-ospeed=TYPE      override type of ospeed variable],
819         [NCURSES_OSPEED="$withval"],
820         [NCURSES_OSPEED=short])
821 AC_MSG_RESULT($NCURSES_OSPEED)
822 AC_SUBST(NCURSES_OSPEED)
823
824 ###   use option --with-mmask-t to override mmask_t's type
825 AC_MSG_CHECKING(for type of mmask_t)
826 AC_ARG_WITH(mmask-t,
827         [  --with-mmask-t=TYPE     override type of mmask_t],
828         [NCURSES_MMASK_T="$withval"],
829         [NCURSES_MMASK_T=auto])
830 AC_MSG_RESULT($NCURSES_MMASK_T)
831
832 ### Enable compiling-in rcs id's
833 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
834 AC_ARG_WITH(rcs-ids,
835         [  --with-rcs-ids          compile-in RCS identifiers],
836         [with_rcs_ids=$withval],
837         [with_rcs_ids=no])
838 AC_MSG_RESULT($with_rcs_ids)
839 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
840
841 ###############################################################################
842 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
843
844 ###############################################################################
845 CF_HELP_MESSAGE(Extensions:)
846
847 ### Note that some functions (such as const) are normally disabled anyway.
848 AC_MSG_CHECKING(if you want to build with function extensions)
849 AC_ARG_ENABLE(ext-funcs,
850         [  --disable-ext-funcs     disable function-extensions],
851         [with_ext_funcs=$enableval],
852         [with_ext_funcs=yes])
853 AC_MSG_RESULT($with_ext_funcs)
854 if test "$with_ext_funcs" = yes ; then
855         NCURSES_EXT_FUNCS=1
856         AC_DEFINE(HAVE_CURSES_VERSION)
857         AC_DEFINE(HAVE_HAS_KEY)
858         AC_DEFINE(HAVE_RESIZETERM)
859         AC_DEFINE(HAVE_RESIZE_TERM)
860         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
861         AC_DEFINE(HAVE_WRESIZE)
862         AC_DEFINE(NCURSES_EXT_FUNCS)
863         GENERATED_EXT_FUNCS=generated
864 else
865         NCURSES_EXT_FUNCS=0
866         GENERATED_EXT_FUNCS=
867 fi
868 AC_SUBST(NCURSES_EXT_FUNCS)
869 AC_SUBST(GENERATED_EXT_FUNCS)
870
871 ###   use option --enable-const to turn on use of const beyond that in XSI.
872 AC_MSG_CHECKING(for extended use of const keyword)
873 AC_ARG_ENABLE(const,
874         [  --enable-const          compile with extra/non-standard const],
875         [with_ext_const=$enableval],
876         [with_ext_const=no])
877 AC_MSG_RESULT($with_ext_const)
878 NCURSES_CONST='/*nothing*/'
879 if test "$with_ext_const" = yes ; then
880         NCURSES_CONST=const
881 fi
882 AC_SUBST(NCURSES_CONST)
883
884 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
885 AC_MSG_CHECKING(if you want to use extended colors)
886 AC_ARG_ENABLE(ext-colors,
887         [  --enable-ext-colors     compile for 256-color support],
888         [with_ext_colors=$enableval],
889         [with_ext_colors=no])
890 AC_MSG_RESULT($with_ext_colors)
891 NCURSES_EXT_COLORS=0
892 if test "$with_ext_colors" = yes ; then
893         if test "$with_widec" != yes ; then
894                 AC_MSG_ERROR(This option applies only to wide-character library)
895         else
896                 # cannot be ABI 5 since it changes sizeof(cchar_t)
897                 CF_NCURSES_ABI_6
898         fi
899         NCURSES_EXT_COLORS=1
900         AC_DEFINE(NCURSES_EXT_COLORS)
901 fi
902 AC_SUBST(NCURSES_EXT_COLORS)
903
904 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
905 AC_MSG_CHECKING(if you want to use extended mouse encoding)
906 AC_ARG_ENABLE(ext-mouse,
907         [  --enable-ext-mouse      compile for extended mouse-encoding],
908         [with_ext_mouse=$enableval],
909         [with_ext_mouse=no])
910 AC_MSG_RESULT($with_ext_mouse)
911 NCURSES_MOUSE_VERSION=1
912 if test "$with_ext_mouse" = yes ; then
913         NCURSES_MOUSE_VERSION=2
914         CF_NCURSES_ABI_6
915 fi
916 AC_SUBST(NCURSES_MOUSE_VERSION)
917
918 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
919 AC_ARG_ENABLE(no-padding,
920         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
921         [with_no_padding=$enableval],
922         [with_no_padding=$with_ext_funcs])
923 AC_MSG_RESULT($with_no_padding)
924 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
925
926 AC_CHECK_SIZEOF([signed char], 0)
927 if test "$ac_cv_sizeof_signed_char" = 1 ; then
928         NCURSES_SBOOL="signed char"
929 else
930         NCURSES_SBOOL="char"
931 fi
932 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
933 AC_ARG_ENABLE(signed-char,
934         [  --enable-signed-char    compile using signed Boolean's in term.h],
935         [with_signed_char=$enableval],
936         [with_signed_char=no])
937 AC_MSG_RESULT($with_signed_char)
938 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
939 AC_SUBST(NCURSES_SBOOL)
940
941 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
942 AC_MSG_CHECKING(if you want SIGWINCH handler)
943 AC_ARG_ENABLE(sigwinch,
944         [  --enable-sigwinch       compile with SIGWINCH handler],
945         [with_sigwinch=$enableval],
946         [with_sigwinch=$with_ext_funcs])
947 AC_MSG_RESULT($with_sigwinch)
948 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
949
950 ###   use option --enable-tcap-names to allow user to define new capabilities
951 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
952 AC_ARG_ENABLE(tcap-names,
953         [  --enable-tcap-names     compile with user-definable terminal capabilities],
954         [with_tcap_names=$enableval],
955         [with_tcap_names=$with_ext_funcs])
956 AC_MSG_RESULT($with_tcap_names)
957 NCURSES_XNAMES=0
958 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
959 AC_SUBST(NCURSES_XNAMES)
960
961 ###############################################################################
962 # These options are relatively safe to experiment with.
963 CF_HELP_MESSAGE(Development Code:)
964 AC_MSG_CHECKING(if you want all development code)
965 AC_ARG_WITH(develop,
966         [  --without-develop       disable development options],
967         [with_develop=$withval],
968         [with_develop=no])
969 AC_MSG_RESULT($with_develop)
970
971 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
972 AC_MSG_CHECKING(if you want hard-tabs code)
973 AC_ARG_ENABLE(hard-tabs,
974         [  --enable-hard-tabs      compile with hard-tabs code],,
975         [enable_hard_tabs=$with_develop])
976 AC_MSG_RESULT($enable_hard_tabs)
977 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
978
979 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
980 AC_MSG_CHECKING(if you want limited support for xmc)
981 AC_ARG_ENABLE(xmc-glitch,
982         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
983         [enable_xmc_glitch=$with_develop])
984 AC_MSG_RESULT($enable_xmc_glitch)
985 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
986
987 ###############################################################################
988 # These are just experimental, probably should not be in a package:
989 CF_HELP_MESSAGE(Experimental Code:)
990
991 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
992 AC_ARG_ENABLE(assumed-color,
993         [  --disable-assumed-color do not assume anything about default-colors],
994         [with_assumed_color=$enableval],
995         [with_assumed_color=yes])
996 AC_MSG_RESULT($with_assumed_color)
997 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
998
999 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1000 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1001 AC_ARG_ENABLE(hashmap,
1002         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1003         [with_hashmap=$enableval],
1004         [with_hashmap=yes])
1005 AC_MSG_RESULT($with_hashmap)
1006 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
1007
1008 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1009 AC_MSG_CHECKING(if you want colorfgbg code)
1010 AC_ARG_ENABLE(colorfgbg,
1011         [  --enable-colorfgbg      compile with $COLORFGBG code],
1012         [with_colorfgbg=$enableval],
1013         [with_colorfgbg=no])
1014 AC_MSG_RESULT($with_colorfgbg)
1015 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
1016
1017 # This is still experimental (20080329), but should ultimately be moved to
1018 # the script-block --with-normal, etc.
1019 CF_WITH_PTHREAD
1020
1021 AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1022 AC_ARG_ENABLE(weak-symbols,
1023     [  --enable-weak-symbols   enable weak-symbols for pthreads],
1024     [use_weak_symbols=$withval],
1025     [use_weak_symbols=no])
1026 AC_MSG_RESULT($use_weak_symbols)
1027 if test "$use_weak_symbols" = yes ; then
1028     CF_WEAK_SYMBOLS
1029 else
1030     cf_cv_weak_symbols=no
1031 fi
1032
1033 if test $cf_cv_weak_symbols = yes ; then
1034     AC_DEFINE(USE_WEAK_SYMBOLS)
1035 fi
1036
1037 PTHREAD=
1038 if test "$with_pthread" = "yes" ; then
1039     AC_DEFINE(USE_PTHREADS)
1040     enable_reentrant=yes
1041     if test $cf_cv_weak_symbols = yes ; then
1042         PTHREAD=-lpthread
1043     fi
1044 fi
1045 AC_SUBST(PTHREAD)
1046
1047 # Reentrant code has to be opaque; there's little advantage to making ncurses
1048 # opaque outside of that, so there is no --enable-opaque option.  We can use
1049 # this option without --with-pthreads, but this will be always set for
1050 # pthreads.
1051 AC_MSG_CHECKING(if you want experimental reentrant code)
1052 AC_ARG_ENABLE(reentrant,
1053         [  --enable-reentrant      compile with experimental reentrant code],
1054         [with_reentrant=$enableval],
1055         [with_reentrant=no])
1056 AC_MSG_RESULT($with_reentrant)
1057 if test "$with_reentrant" = yes ; then
1058         cf_cv_enable_reentrant=1
1059         cf_cv_enable_opaque="NCURSES_INTERNALS"
1060         NCURSES_OPAQUE=1
1061         NCURSES_SIZE_T=int
1062     if test $cf_cv_weak_symbols = yes ; then
1063         CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1064     else
1065         LIB_SUFFIX="t${LIB_SUFFIX}"
1066     fi
1067         AC_DEFINE(USE_REENTRANT)
1068         CF_NCURSES_ABI_6
1069 else
1070         cf_cv_enable_reentrant=0
1071         cf_cv_enable_opaque="NCURSES_OPAQUE"
1072         NCURSES_OPAQUE=0
1073         NCURSES_SIZE_T=short
1074 fi
1075 AC_SUBST(cf_cv_enable_reentrant)
1076 AC_SUBST(cf_cv_enable_opaque)
1077 AC_SUBST(NCURSES_OPAQUE)
1078 AC_SUBST(NCURSES_SIZE_T)
1079
1080 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1081 AC_ARG_ENABLE(safe-sprintf,
1082         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1083         [with_safe_sprintf=$enableval],
1084         [with_safe_sprintf=no])
1085 AC_MSG_RESULT($with_safe_sprintf)
1086 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1087
1088 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1089 # when hashmap is used scroll hints are useless
1090 if test "$with_hashmap" = no ; then
1091 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1092 AC_ARG_ENABLE(scroll-hints,
1093         [  --disable-scroll-hints  compile without scroll-hints code],
1094         [with_scroll_hints=$enableval],
1095         [with_scroll_hints=yes])
1096 AC_MSG_RESULT($with_scroll_hints)
1097 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1098 fi
1099
1100 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1101 AC_ARG_ENABLE(wgetch-events,
1102         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1103         [with_wgetch_events=$enableval],
1104         [with_wgetch_events=no])
1105 AC_MSG_RESULT($with_wgetch_events)
1106 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1107
1108 ###############################################################################
1109 CF_HELP_MESSAGE(Testing/development Options:)
1110
1111 ###     use option --disable-echo to suppress full display compiling commands
1112 AC_MSG_CHECKING(if you want to display full commands during build)
1113 AC_ARG_ENABLE(echo,
1114         [  --enable-echo           build: display "compiling" commands (default)],
1115         [with_echo=$enableval],
1116         [with_echo=yes])
1117 if test "$with_echo" = yes; then
1118         ECHO_LINK=
1119 else
1120         ECHO_LINK='@ echo linking $@ ... ;'
1121         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1122         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1123 fi
1124 AC_MSG_RESULT($with_echo)
1125 AC_SUBST(ECHO_LINK)
1126
1127 ###     use option --enable-warnings to turn on all gcc warnings
1128 AC_MSG_CHECKING(if you want to see compiler warnings)
1129 AC_ARG_ENABLE(warnings,
1130         [  --enable-warnings       build: turn on GCC compiler warnings],
1131         [with_warnings=$enableval])
1132 AC_MSG_RESULT($with_warnings)
1133
1134 if test "x$with_warnings" = "xyes"; then
1135         ADAFLAGS="$ADAFLAGS -gnatg"
1136         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1137         if test "$cf_with_cxx" = yes ; then
1138                 CF_GXX_WARNINGS(Wno-unused)
1139         fi
1140 fi
1141 CF_GCC_ATTRIBUTES
1142
1143 ###     use option --enable-assertions to turn on generation of assertion code
1144 AC_MSG_CHECKING(if you want to enable runtime assertions)
1145 AC_ARG_ENABLE(assertions,
1146         [  --enable-assertions     test: turn on generation of assertion code],
1147         [with_assertions=$enableval],
1148         [with_assertions=no])
1149 AC_MSG_RESULT($with_assertions)
1150 if test -n "$GCC"
1151 then
1152         if test "$with_assertions" = no
1153         then
1154                 AC_DEFINE(NDEBUG)
1155                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1156         else
1157                 ADAFLAGS="$ADAFLAGS -gnata"
1158         fi
1159 fi
1160
1161 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1162 CF_DISABLE_LEAKS
1163 AC_DEFINE(HAVE_NC_ALLOC_H)
1164
1165 ###     use option --enable-expanded to generate certain macros as functions
1166 AC_ARG_ENABLE(expanded,
1167         [  --enable-expanded       test: generate functions for certain macros],
1168         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1169
1170 ###     use option --disable-macros to suppress macros in favor of functions
1171 AC_ARG_ENABLE(macros,
1172         [  --disable-macros        test: use functions rather than macros],
1173         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1174
1175 # Normally we only add trace() to the debug-library.  Allow this to be
1176 # extended to all models of the ncurses library:
1177 cf_all_traces=no
1178 case "$CFLAGS $CPPFLAGS" in
1179 *-DTRACE*)
1180         cf_all_traces=yes
1181         ;;
1182 esac
1183
1184 AC_MSG_CHECKING(whether to add trace feature to all models)
1185 AC_ARG_WITH(trace,
1186 [  --with-trace            test: add trace() function to all models of ncurses],
1187 [cf_with_trace=$withval],
1188 [cf_with_trace=$cf_all_traces])
1189 AC_MSG_RESULT($cf_with_trace)
1190
1191 if test "$cf_with_trace" = yes ; then
1192         LIB_TRACING=all
1193         ADA_TRACE=TRUE
1194         CF_ADD_CFLAGS(-DTRACE)
1195 else
1196         LIB_TRACING=DEBUG
1197         ADA_TRACE=FALSE
1198 fi
1199
1200 AC_SUBST(ADA_TRACE)
1201
1202 ###     Checks for libraries.
1203 AC_CHECK_FUNC(gettimeofday,
1204         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1205
1206 AC_CHECK_LIB(bsd, gettimeofday,
1207         AC_DEFINE(HAVE_GETTIMEOFDAY)
1208         LIBS="$LIBS -lbsd")])dnl CLIX: bzero, select, gettimeofday
1209
1210 CF_MATH_LIB(MATH_LIB,sin(x))
1211 AC_SUBST(MATH_LIB)
1212
1213 ###     Checks for header files.
1214 AC_STDC_HEADERS
1215 AC_HEADER_DIRENT
1216 AC_HEADER_TIME
1217 CF_REGEX
1218
1219 dnl These are some other potentially nonportable headers.
1220 AC_CHECK_HEADERS( \
1221 fcntl.h \
1222 getopt.h \
1223 limits.h \
1224 locale.h \
1225 poll.h \
1226 sys/bsdtypes.h \
1227 sys/ioctl.h \
1228 sys/param.h \
1229 sys/poll.h \
1230 sys/select.h \
1231 sys/time.h \
1232 sys/times.h \
1233 ttyent.h \
1234 unistd.h \
1235 wctype.h \
1236 )
1237
1238 # check for ISC (this may also define _POSIX_SOURCE)
1239 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1240 if test "$ISC" = yes ; then
1241         AC_CHECK_LIB(cposix,main)
1242         AC_CHECK_LIB(inet,bzero,LIBS="$LIBS -linet")dnl also 'select()'
1243 fi
1244
1245 CF_SYS_TIME_SELECT
1246
1247 ###     checks for compiler characteristics
1248 AC_LANG_C
1249 AC_C_CONST
1250 CF_C_INLINE(NCURSES_INLINE,1200)
1251 CF_SIG_ATOMIC_T
1252
1253 if test $NCURSES_CHTYPE = auto ; then
1254         CF_TYPEOF_CHTYPE
1255 else
1256         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1257 fi
1258 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1259 AC_SUBST(cf_cv_typeof_chtype)
1260
1261 CF_UNSIGNED_LITERALS
1262 cf_cv_1UL="1"
1263 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1264 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1265 AC_SUBST(cf_cv_1UL)
1266
1267 if test $NCURSES_MMASK_T = auto ; then
1268         cf_cv_typeof_mmask_t=long
1269 else
1270         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1271 fi
1272 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1273 AC_SUBST(cf_cv_typeof_mmask_t)
1274
1275 ###     Checks for external-data
1276 CF_ERRNO
1277 CF_LINK_DATAONLY
1278
1279 ###     Checks for library functions.
1280 AC_CHECK_FUNCS( \
1281 getcwd \
1282 getegid \
1283 geteuid \
1284 getttynam \
1285 issetugid \
1286 poll \
1287 remove \
1288 select \
1289 setbuf \
1290 setbuffer \
1291 setvbuf \
1292 sigaction \
1293 sigvec \
1294 strdup \
1295 strstr \
1296 tcgetpgrp \
1297 times \
1298 vsnprintf \
1299 )
1300 if test "$with_getcap" = "yes" ; then
1301         CF_CGETENT
1302 fi
1303
1304 CF_ISASCII
1305 CF_STRUCT_SIGACTION
1306 CF_FUNC_NANOSLEEP
1307 CF_FUNC_TERMIOS
1308 CF_FUNC_VSSCANF
1309 CF_MKSTEMP
1310
1311 # setup for prototype of fallback for vsscanf()
1312 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1313
1314 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1315 if test "$cross_compiling" = yes ; then
1316         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1317 else
1318         AC_FUNC_SETVBUF_REVERSED
1319 fi
1320 AC_TYPE_SIGNAL
1321 CF_TYPE_SIGACTION
1322 CF_SIZECHANGE
1323 CF_FUNC_MEMMOVE
1324 CF_FUNC_POLL
1325
1326 # special check for test/ditto.c
1327 CF_FUNC_OPENPTY
1328 if test "$cf_cv_func_openpty" != no ; then
1329     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1330     AC_DEFINE(USE_XTERM_PTY)
1331     if test "$cf_cv_lib_util" = yes ; then
1332         TEST_LIBS="-lutil $TEST_LIBS"
1333     fi
1334 fi
1335 AC_SUBST(TEST_LIBS)
1336
1337 if test "$with_hashed_db" != no ; then
1338         AC_DEFINE(USE_HASHED_DB)
1339         CF_HASHED_DB($with_hashed_db)
1340 fi
1341
1342 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1343 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1344         CF_STRIP_G_OPT(CFLAGS)
1345         CF_STRIP_G_OPT(CXXFLAGS)
1346 fi
1347
1348 # Just in case, check if the C compiler has a bool type.
1349 CF_BOOL_DECL(cf_cv_cc_bool_type)
1350
1351 # Check for C++ compiler characteristics (and ensure that it's there!)
1352 if test -n "$CXX" ; then
1353         AC_LANG_CPLUSPLUS
1354         CF_STDCPP_LIBRARY
1355         CF_PROG_CC_C_O(CXX)
1356
1357         case $GXX_VERSION in
1358         1*|2.[0-6]*)
1359                 cf_cxx_library=yes
1360                 ;;
1361         *-2.7*|2.7*)
1362                 CF_GPP_LIBRARY
1363                 ;;
1364         *)
1365                 cf_cxx_library=no
1366                 ;;
1367         esac
1368
1369         AC_CHECK_HEADERS(iostream typeinfo)
1370
1371     if test x"$ac_cv_header_iostream" = xyes ; then
1372         AC_MSG_CHECKING(if iostream uses std-namespace)
1373         AC_TRY_COMPILE([
1374 #include <iostream>
1375 using std::endl;
1376 using std::cerr;],[
1377 cerr << "testing" << endl;
1378 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1379         AC_MSG_RESULT($cf_iostream_namespace)
1380         if test "$cf_iostream_namespace" = yes ; then
1381             AC_DEFINE(IOSTREAM_NAMESPACE)
1382         fi
1383     fi
1384
1385         CF_BOOL_DECL
1386         CF_BOOL_SIZE
1387         CF_ETIP_DEFINES
1388         CF_CPP_PARAM_INIT
1389         CF_CPP_STATIC_CAST
1390
1391         CXX_AR='$(AR)'
1392         CXX_ARFLAGS='$(ARFLAGS)'
1393         case $cf_cv_system_name in #(vi
1394         irix*) #(vi
1395             if test "$GXX" != yes ; then
1396                 CXX_AR='$(CXX)'
1397                 CXX_ARFLAGS='-ar -o'
1398             fi
1399             ;;
1400         sco3.2v5*) #(vi
1401             CXXLDFLAGS="-u main"
1402             ;;
1403         solaris2*)
1404             if test "$GXX" != yes ; then
1405                 CXX_AR='$(CXX)'
1406                 CXX_ARFLAGS='-xar -o'
1407             fi
1408             ;;
1409         esac
1410         AC_SUBST(CXXLDFLAGS)
1411         AC_SUBST(CXX_AR)
1412         AC_SUBST(CXX_ARFLAGS)
1413 else
1414         cf_cxx_library=no
1415         cf_cv_builtin_bool=1
1416
1417         # Just because we are not configuring against C++ right now does not
1418         # mean that a user will not want to use C++.  Some distributors disable
1419         # the C++ portion of this configuration as a shortcut (or just to avoid
1420         # compiling the demo in the c++ directory).  So we need a reasonable
1421         # default for the 'bool' type.
1422         #
1423         # Caveat: since the storage of the bool type is not standardized, it
1424         # may change.
1425
1426         if test "$NCURSES_BOOL" != auto ; then
1427                 cf_cv_type_of_bool=$NCURSES_BOOL
1428                 cf_cv_header_stdbool_h=0
1429         else
1430                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1431                         CF_BOOL_SIZE
1432                 else
1433                         AC_MSG_CHECKING(for fallback type of bool)
1434                         case "$host_cpu" in #(vi
1435                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1436                         *)      cf_cv_type_of_bool=int  ;;
1437                         esac
1438                         AC_MSG_RESULT($cf_cv_type_of_bool)
1439                 fi
1440         fi
1441 fi
1442 AC_SUBST(CXXLIBS)
1443
1444 # If the C compiler did not declare bool, and we did not determine that the C++
1445 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1446 # ncurses library use the same type as C++ bool.  Note that this allows one to
1447 # specify the type of bool in a configure-script option and postpone
1448 # integration with the C++ compiler provided that the types are compatible.
1449 USE_CXX_BOOL=1
1450 if test $cf_cv_cc_bool_type = 1
1451 then
1452         # oops: C has a bool.  Unlikely, but C++ could differ.
1453         USE_CXX_BOOL=0
1454 elif test $cf_cv_builtin_bool = 0
1455 then
1456         # C++ has no bool
1457         USE_CXX_BOOL=0
1458 else
1459         # this is the normal case
1460         USE_CXX_BOOL='defined(__cplusplus)'
1461 fi
1462 AC_SUBST(USE_CXX_BOOL)
1463
1464 CF_HELP_MESSAGE(Ada95 Binding Options:)
1465
1466 dnl If the Ada95 source-tree is present, add that to the build unless it will
1467 dnl not work, or was not requested.
1468 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1469
1470 dnl libtool does not know anything about GNAT, though a change made in 1998
1471 dnl provided for it "someday".  Disable the ada subtree if we are using
1472 dnl libtool -TD 20070714
1473 if test "$cf_with_ada" != "no" ; then
1474     if test "$with_libtool" != "no"; then
1475         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1476         cf_with_ada=no
1477     fi
1478 fi
1479
1480 dnl Check for availability of GNU Ada Translator (GNAT).
1481 dnl At the moment we support no other Ada95 compiler.
1482 if test "$cf_with_ada" != "no" ; then
1483 cf_ada_make=gnatmake
1484 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
1485 if test "$ac_cv_prog_gnat_exists" = no; then
1486    cf_ada_make=
1487 else
1488    CF_GNAT_VERSION
1489    AC_CHECK_PROG(M4_exists, m4, yes, no)
1490    if test "$ac_cv_prog_M4_exists" = no; then
1491       cf_cv_prog_gnat_correct=no
1492       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
1493    fi
1494    if test "$cf_cv_prog_gnat_correct" = yes; then
1495       AC_MSG_CHECKING(if GNAT works)
1496       CF_GNAT_TRY_RUN([procedure conftest;],
1497 [with Text_IO;
1498 with GNAT.OS_Lib;
1499 procedure conftest is
1500 begin
1501    Text_IO.Put ("Hello World");
1502    Text_IO.New_Line;
1503    GNAT.OS_Lib.OS_Exit (0);
1504 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
1505       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
1506    fi
1507 fi
1508 if test "$cf_cv_prog_gnat_correct" = yes; then
1509    ADAFLAGS="-O3 -gnatpn $ADAFLAGS"
1510
1511    AC_MSG_CHECKING(if GNAT pragma Unreferenced works)
1512    CF_GNAT_TRY_LINK([procedure conftest;],
1513 [with Text_IO;
1514 with GNAT.OS_Lib;
1515 procedure conftest is
1516    test : Integer;
1517    pragma Unreferenced (test);
1518 begin
1519    test := 1;
1520    Text_IO.Put ("Hello World");
1521    Text_IO.New_Line;
1522    GNAT.OS_Lib.OS_Exit (0);
1523 end conftest;],[cf_cv_pragma_unreferenced=yes],[cf_cv_pragma_unreferenced=no])
1524    AC_MSG_RESULT($cf_cv_pragma_unreferenced)
1525
1526    # if the pragma is supported, use it (needed in the Trace code).
1527    if test $cf_cv_pragma_unreferenced = yes ; then
1528       PRAGMA_UNREF=TRUE
1529    else
1530       PRAGMA_UNREF=FALSE
1531    fi
1532
1533    AC_ARG_WITH(ada-compiler,
1534         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
1535         [cf_ada_compiler=$withval],
1536         [cf_ada_compiler=gnatmake])
1537
1538    cf_ada_package=terminal_interface
1539
1540    AC_SUBST(cf_ada_make)
1541    AC_SUBST(cf_ada_compiler)
1542    AC_SUBST(cf_ada_package)
1543    AC_SUBST(ADAFLAGS)
1544    AC_SUBST(cf_compile_generics)
1545    AC_SUBST(cf_generic_objects)
1546    AC_SUBST(PRAGMA_UNREF)
1547
1548    CF_WITH_PATH(ada-include,
1549        [  --with-ada-include=DIR  Ada includes are in DIR],
1550        ADA_INCLUDE,
1551        PREFIX/lib/ada/adainclude,
1552        [$]prefix/lib/ada/adainclude)
1553    AC_SUBST(ADA_INCLUDE)
1554
1555    CF_WITH_PATH(ada-objects,
1556        [  --with-ada-objects=DIR  Ada objects are in DIR],
1557        ADA_OBJECTS,
1558        PREFIX/lib/ada/adalib,
1559        [$]prefix/lib/ada/adalib)
1560    AC_SUBST(ADA_OBJECTS)
1561
1562 fi
1563 fi
1564 else
1565    cf_with_ada=no
1566 fi
1567
1568 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1569 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1570 ###
1571 ### ticlib modules may be a separate library, otherwise contained in termlib.
1572 ### termlib modules may be a separate library, otherwise contained in ncurses.
1573 ###
1574 ### The of "+" or " " between the tokens controls the way the script
1575 ### chooses to split module lists into libraries.
1576 ###
1577 ### (see CF_LIB_RULES).
1578 AC_MSG_CHECKING(for library subsets)
1579 LIB_SUBSETS=
1580
1581 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1582         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1583         if test "$with_ticlib" != no ; then
1584                 LIB_SUBSETS="${LIB_SUBSETS} "
1585         else
1586                 LIB_SUBSETS="${LIB_SUBSETS}+"
1587         fi
1588 fi
1589
1590 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1591 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1592 if test "$with_termlib" != no ; then
1593         LIB_SUBSETS="${LIB_SUBSETS} "
1594 else
1595         LIB_SUBSETS="${LIB_SUBSETS}+"
1596 fi
1597
1598 LIB_SUBSETS="${LIB_SUBSETS}base"
1599 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1600 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1601
1602 AC_MSG_RESULT($LIB_SUBSETS)
1603
1604 ### Construct the list of include-directories to be generated
1605 CF_INCLUDE_DIRS
1606 CF_ADA_INCLUDE_DIRS
1607
1608 ### Build up pieces for makefile rules
1609 AC_MSG_CHECKING(default library suffix)
1610 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1611 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1612 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1613
1614 AC_MSG_CHECKING(default library-dependency suffix)
1615 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1616 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1617 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1618
1619 AC_MSG_CHECKING(default object directory)
1620 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1621 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1622 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1623
1624 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1625 if test "$cf_with_cxx" = yes ; then
1626 AC_MSG_CHECKING(c++ library-dependency suffix)
1627 if test "$with_libtool" != "no"; then
1628         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1629 else
1630         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)dnl we normally make a static library
1631 fi
1632 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1633 AC_SUBST(CXX_LIB_SUFFIX)
1634 fi
1635
1636 # do not want -ldl in build except as needed for -lncurses dependency
1637 if test "$with_dlsym" = yes ; then
1638 if test $DFT_LWR_MODEL = shared || \
1639    test $DFT_LWR_MODEL = libtool ; then
1640         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1641 fi
1642 fi
1643 ### Set up low-level terminfo dependencies for makefiles.
1644
1645 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1646 # do not need libdl
1647 TICS_LIST=
1648 if test "$with_dlsym" = yes ; then
1649         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1650 fi
1651
1652 if test "$with_ticlib" != no ; then
1653
1654         if test "$with_ticlib" != yes ; then
1655                 TICS_NAME=$with_ticlib
1656                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1657                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1658                 TICS_LIB_SUFFIX="${with_ticlib}"
1659         else
1660                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1661                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1662                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1663         fi
1664         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1665 else
1666         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1667 fi
1668 AC_SUBST(TICS_ARG_SUFFIX)
1669 AC_SUBST(TICS_DEP_SUFFIX)
1670 AC_SUBST(TICS_LIB_SUFFIX)
1671 AC_SUBST(TICS_ARGS)
1672
1673 if test "$with_termlib" != no ; then
1674
1675         if test "$with_termlib" != yes ; then
1676                 TINFO_NAME=$with_termlib
1677                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1678                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1679                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1680                 TINFO_LIB_SUFFIX="${with_termlib}"
1681         else
1682                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1683                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1684                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1685                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1686         fi
1687
1688         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1689         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1690         if test "$DFT_LWR_MODEL" = "libtool"; then
1691                 TEST_ARGS="${TEST_DEPS}"
1692                 TEST_ARG2="${TEST_DEP2}"
1693                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1694         else
1695                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1696                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1697                 TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1698                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1699                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1700         fi
1701 else
1702         # the next lines are needed for linking libtic over libncurses
1703         TINFO_NAME=${LIB_NAME}
1704         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1705         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1706         if test "$with_tic_depends" = yes ; then
1707                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1708         else
1709                 TICS_LIST="$SHLIB_LIST"
1710         fi
1711
1712         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1713 fi
1714
1715 if test "$DFT_LWR_MODEL" = shared ; then
1716         case $cf_cv_system_name in #(vi
1717         cygwin*)
1718                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1719                 TINFO_SUFFIX=.dll
1720                 ;;
1721         esac
1722 fi
1723
1724 AC_SUBST(TINFO_ARG_SUFFIX)
1725 AC_SUBST(TINFO_DEP_SUFFIX)
1726 AC_SUBST(TINFO_LIB_SUFFIX)
1727 AC_SUBST(TINFO_ARGS)
1728
1729 if test "$with_dlsym" = yes ; then
1730         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1731 fi
1732
1733 if test "$DFT_LWR_MODEL" = "libtool"; then
1734     OBJEXT=lo
1735 fi
1736
1737 # needed for Ada95
1738 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1739 AC_SUBST(TINFO_ARGS2)
1740
1741 case $DFT_LWR_MODEL in
1742 normal|debug|profile)
1743         CF_LDFLAGS_STATIC
1744         ;;
1745 esac
1746
1747 AC_MSG_CHECKING(where we will install curses.h)
1748 test "$with_overwrite" = no && \
1749 test "x$includedir" = 'x${prefix}/include' && \
1750         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1751 AC_MSG_RESULT($includedir)
1752
1753 ### Resolve a conflict between normal and wide-curses by forcing applications
1754 ### that will need libutf8 to add it to their configure script.
1755 if test "$with_overwrite" != no ; then
1756 if test "$NCURSES_LIBUTF8" = 1 ; then
1757         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1758         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1759 fi
1760 fi
1761 WITH_OVERWRITE=$with_overwrite
1762
1763 AC_SUBST(WITH_OVERWRITE)
1764 AC_SUBST(TICS_LIST)
1765 AC_SUBST(TINFO_LIST)
1766 AC_SUBST(SHLIB_LIST)
1767
1768 # used to separate tack out of the tree
1769 NCURSES_TREE=
1770 AC_SUBST(NCURSES_TREE)
1771
1772 ### predefined stuff for the test programs
1773 AC_DEFINE(HAVE_SLK_COLOR)
1774
1775 ### Construct the list of subdirectories for which we'll customize makefiles
1776 ### with the appropriate compile-rules.
1777
1778 CF_SRC_MODULES($modules_to_build)
1779
1780 if test "$cf_with_ada" != "no" && test "$cf_cv_prog_gnat_correct" != "no"; then
1781    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses-config"
1782 fi
1783
1784 CF_DIRS_TO_MAKE
1785
1786 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATHSEP')
1787
1788 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1789
1790 ### Now that we're done running tests, add the compiler-warnings, if any
1791 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1792
1793 ### If we're building with rpath, try to link non-standard libs that way too.
1794 if test "$DFT_LWR_MODEL" = "shared"; then
1795   CF_RPATH_HACK
1796 fi
1797
1798 ### Define substitutions for header files to avoid name-pollution
1799 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1800 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1801 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1802
1803 ################################################################################
1804 test "$use_database" = yes && \
1805 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1806
1807 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1808
1809 if test x"$enable_pc_files" = xyes ; then \
1810 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1811 MAKE_PC_FILES=
1812 else
1813 MAKE_PC_FILES="#"
1814 fi
1815 AC_SUBST(MAKE_PC_FILES)
1816
1817 AC_OUTPUT( \
1818         include/MKterm.h.awk \
1819         include/curses.head:include/curses.h.in \
1820         include/termcap.h \
1821         include/unctrl.h \
1822         $SUB_MAKEFILES \
1823         Makefile,[
1824 CF_PRG_RULES([$srcdir/test/mk-test.awk ECHO_LINK="$ECHO_LINK"], test)
1825 CF_LIB_RULES($SRC_SUBDIRS)
1826 ],[
1827 ### Special initialization commands, used to pass information from the
1828 ### configuration-run into config.status
1829
1830 AWK="$AWK"
1831 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1832 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1833 ECHO_LINK="$ECHO_LINK"
1834 LDCONFIG="$LDCONFIG"
1835 LIB_NAME="$LIB_NAME"
1836 LIB_SUBSETS="$LIB_SUBSETS"
1837 LIB_SUFFIX="$LIB_SUFFIX"
1838 LIB_TRACING="$LIB_TRACING"
1839 MAKE_TERMINFO="$MAKE_TERMINFO"
1840 NCURSES_MAJOR="$NCURSES_MAJOR"
1841 NCURSES_MINOR="$NCURSES_MINOR"
1842 NCURSES_OSPEED="$NCURSES_OSPEED"
1843 NCURSES_PATCH="$NCURSES_PATCH"
1844 SRC_SUBDIRS="$SRC_SUBDIRS"
1845 TERMINFO="$TERMINFO"
1846 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1847 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1848 TICS_NAME="$TICS_NAME"
1849 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1850 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1851 TINFO_NAME="$TINFO_NAME"
1852 TINFO_SUFFIX="$TINFO_SUFFIX"
1853 WITH_CURSES_H="$with_curses_h"
1854 WITH_ECHO="$with_echo"
1855 WITH_OVERWRITE="$with_overwrite"
1856 cf_LIST_MODELS="$cf_list_models"
1857 cf_cv_abi_version="$cf_cv_abi_version"
1858 cf_cv_do_relink="$cf_cv_do_relink"
1859 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1860 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1861 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1862 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1863 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1864 cf_cv_rel_version="$cf_cv_rel_version"
1865 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1866 cf_cv_shared_soname='$cf_cv_shared_soname'
1867 cf_cv_shlib_version="$cf_cv_shlib_version"
1868 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1869 cf_cv_system_name="$cf_cv_system_name"
1870 cf_with_cxx_binding="$cf_with_cxx_binding"
1871 cf_with_manpages="$cf_with_manpages"
1872 host="$host"
1873 target="$target"
1874
1875 ],cat)dnl
1876 ${MAKE-make} preinstall