ncurses 5.9 - patch 20140607
[ncurses.git] / Ada95 / aclocal.m4
1 dnl***************************************************************************
2 dnl Copyright (c) 2010-2013,2014 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey
30 dnl
31 dnl $Id: aclocal.m4,v 1.86 2014/06/01 15:36:34 tom Exp $
32 dnl Macros used in NCURSES Ada95 auto-configuration script.
33 dnl
34 dnl These macros are maintained separately from NCURSES.  The copyright on
35 dnl this file applies to the aggregation of macros and does not affect use of
36 dnl these macros in other applications.
37 dnl
38 dnl See http://invisible-island.net/autoconf/ for additional information.
39 dnl
40 dnl ---------------------------------------------------------------------------
41 dnl ---------------------------------------------------------------------------
42 dnl CF_ACVERSION_CHECK version: 4 updated: 2013/03/04 19:52:56
43 dnl ------------------
44 dnl Conditionally generate script according to whether we're using a given autoconf.
45 dnl
46 dnl $1 = version to compare against
47 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
48 dnl $3 = code to use if AC_ACVERSION is older than $1.
49 define([CF_ACVERSION_CHECK],
50 [
51 ifdef([AC_ACVERSION], ,[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])dnl
52 ifdef([m4_version_compare],
53 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
54 [CF_ACVERSION_COMPARE(
55 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
56 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
57 dnl ---------------------------------------------------------------------------
58 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
59 dnl --------------------
60 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
61 dnl                      MAJOR2, MINOR2, TERNARY2,
62 dnl                      PRINTABLE2, not FOUND, FOUND)
63 define([CF_ACVERSION_COMPARE],
64 [ifelse(builtin([eval], [$2 < $5]), 1,
65 [ifelse([$8], , ,[$8])],
66 [ifelse([$9], , ,[$9])])])dnl
67 dnl ---------------------------------------------------------------------------
68 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
69 dnl -------------------
70 dnl Construct the list of include-options for the C programs in the Ada95
71 dnl binding.
72 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
73 [
74 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
75 if test "$srcdir" != "."; then
76         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
77 fi
78 if test "$GCC" != yes; then
79         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
80 elif test "$includedir" != "/usr/include"; then
81         if test "$includedir" = '${prefix}/include' ; then
82                 if test x$prefix != x/usr ; then
83                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
84                 fi
85         else
86                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
87         fi
88 fi
89 AC_SUBST(ACPPFLAGS)
90 ])dnl
91 dnl ---------------------------------------------------------------------------
92 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
93 dnl ---------------
94 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
95 AC_DEFUN([CF_ADD_ADAFLAGS],[
96         ADAFLAGS="$ADAFLAGS $1"
97         AC_SUBST(ADAFLAGS)
98 ])dnl
99 dnl ---------------------------------------------------------------------------
100 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
101 dnl -------------
102 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
103 dnl The second parameter if given makes this macro verbose.
104 dnl
105 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
106 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
107 dnl confused by the quotes (which require backslashes to keep them usable).
108 AC_DEFUN([CF_ADD_CFLAGS],
109 [
110 cf_fix_cppflags=no
111 cf_new_cflags=
112 cf_new_cppflags=
113 cf_new_extra_cppflags=
114
115 for cf_add_cflags in $1
116 do
117 case $cf_fix_cppflags in
118 no)
119         case $cf_add_cflags in #(vi
120         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
121                 case $cf_add_cflags in
122                 -D*)
123                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
124
125                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
126                                 && test -z "${cf_tst_cflags}" \
127                                 && cf_fix_cppflags=yes
128
129                         if test $cf_fix_cppflags = yes ; then
130                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
131                                 continue
132                         elif test "${cf_tst_cflags}" = "\"'" ; then
133                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
134                                 continue
135                         fi
136                         ;;
137                 esac
138                 case "$CPPFLAGS" in
139                 *$cf_add_cflags) #(vi
140                         ;;
141                 *) #(vi
142                         case $cf_add_cflags in #(vi
143                         -D*)
144                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
145                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
146                                 ;;
147                         esac
148                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
149                         ;;
150                 esac
151                 ;;
152         *)
153                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
154                 ;;
155         esac
156         ;;
157 yes)
158         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
159
160         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
161
162         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
163                 && test -z "${cf_tst_cflags}" \
164                 && cf_fix_cppflags=no
165         ;;
166 esac
167 done
168
169 if test -n "$cf_new_cflags" ; then
170         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
171         CFLAGS="$CFLAGS $cf_new_cflags"
172 fi
173
174 if test -n "$cf_new_cppflags" ; then
175         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
176         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
177 fi
178
179 if test -n "$cf_new_extra_cppflags" ; then
180         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
181         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
182 fi
183
184 AC_SUBST(EXTRA_CPPFLAGS)
185
186 ])dnl
187 dnl ---------------------------------------------------------------------------
188 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
189 dnl -------------
190 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
191 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
192 dnl but old versions (and some misinstalled ones) need that.  To make things
193 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
194 dnl the include-path).
195 AC_DEFUN([CF_ADD_INCDIR],
196 [
197 if test -n "$1" ; then
198   for cf_add_incdir in $1
199   do
200         while test $cf_add_incdir != /usr/include
201         do
202           if test -d $cf_add_incdir
203           then
204                 cf_have_incdir=no
205                 if test -n "$CFLAGS$CPPFLAGS" ; then
206                   # a loop is needed to ensure we can add subdirs of existing dirs
207                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
208                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
209                           cf_have_incdir=yes; break
210                         fi
211                   done
212                 fi
213
214                 if test "$cf_have_incdir" = no ; then
215                   if test "$cf_add_incdir" = /usr/local/include ; then
216                         if test "$GCC" = yes
217                         then
218                           cf_save_CPPFLAGS=$CPPFLAGS
219                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
220                           AC_TRY_COMPILE([#include <stdio.h>],
221                                   [printf("Hello")],
222                                   [],
223                                   [cf_have_incdir=yes])
224                           CPPFLAGS=$cf_save_CPPFLAGS
225                         fi
226                   fi
227                 fi
228
229                 if test "$cf_have_incdir" = no ; then
230                   CF_VERBOSE(adding $cf_add_incdir to include-path)
231                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
232
233                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
234                   test "$cf_top_incdir" = "$cf_add_incdir" && break
235                   cf_add_incdir="$cf_top_incdir"
236                 else
237                   break
238                 fi
239           fi
240         done
241   done
242 fi
243 ])dnl
244 dnl ---------------------------------------------------------------------------
245 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
246 dnl ----------
247 dnl Add a library, used to enforce consistency.
248 dnl
249 dnl $1 = library to add, without the "-l"
250 dnl $2 = variable to update (default $LIBS)
251 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
252 dnl ---------------------------------------------------------------------------
253 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
254 dnl -------------
255 dnl     Adds to the library-path
256 dnl
257 dnl     Some machines have trouble with multiple -L options.
258 dnl
259 dnl $1 is the (list of) directory(s) to add
260 dnl $2 is the optional name of the variable to update (default LDFLAGS)
261 dnl
262 AC_DEFUN([CF_ADD_LIBDIR],
263 [
264 if test -n "$1" ; then
265   for cf_add_libdir in $1
266   do
267     if test $cf_add_libdir = /usr/lib ; then
268       :
269     elif test -d $cf_add_libdir
270     then
271       cf_have_libdir=no
272       if test -n "$LDFLAGS$LIBS" ; then
273         # a loop is needed to ensure we can add subdirs of existing dirs
274         for cf_test_libdir in $LDFLAGS $LIBS ; do
275           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
276             cf_have_libdir=yes; break
277           fi
278         done
279       fi
280       if test "$cf_have_libdir" = no ; then
281         CF_VERBOSE(adding $cf_add_libdir to library-path)
282         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
283       fi
284     fi
285   done
286 fi
287 ])dnl
288 dnl ---------------------------------------------------------------------------
289 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
290 dnl -----------
291 dnl Add one or more libraries, used to enforce consistency.
292 dnl
293 dnl $1 = libraries to add, with the "-l", etc.
294 dnl $2 = variable to update (default $LIBS)
295 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
296 dnl ---------------------------------------------------------------------------
297 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
298 dnl ------------------
299 dnl Append to a search-list for a nonstandard header/lib-file
300 dnl     $1 = the variable to return as result
301 dnl     $2 = the package name
302 dnl     $3 = the subdirectory, e.g., bin, include or lib
303 dnl $4 = the directory under which we will test for subdirectories
304 dnl $5 = a directory that we do not want $4 to match
305 AC_DEFUN([CF_ADD_SUBDIR_PATH],
306 [
307 test "x$4" != "x$5" && \
308 test -d "$4" && \
309 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
310         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
311         test -d $4/$3 &&          $1="[$]$1 $4/$3"
312         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
313         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
314         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
315         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
316 }
317 ])dnl
318 dnl ---------------------------------------------------------------------------
319 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
320 dnl --------------
321 dnl Allow user to disable a normally-on option.
322 AC_DEFUN([CF_ARG_DISABLE],
323 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
324 dnl ---------------------------------------------------------------------------
325 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
326 dnl -------------
327 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
328 dnl values.
329 dnl
330 dnl Parameters:
331 dnl $1 = option name
332 dnl $2 = help-string
333 dnl $3 = action to perform if option is not default
334 dnl $4 = action if perform if option is default
335 dnl $5 = default option value (either 'yes' or 'no')
336 AC_DEFUN([CF_ARG_OPTION],
337 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
338   if test "$enableval" != "$5" ; then
339 ifelse([$3],,[    :]dnl
340 ,[    $3]) ifelse([$4],,,[
341   else
342     $4])
343   fi],[enableval=$5 ifelse([$4],,,[
344   $4
345 ])dnl
346   ])])dnl
347 dnl ---------------------------------------------------------------------------
348 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
349 dnl -----------
350 dnl Check for suitable "ar" (archiver) options for updating an archive.
351 AC_DEFUN([CF_AR_FLAGS],[
352 AC_REQUIRE([CF_PROG_AR])
353
354 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
355         cf_cv_ar_flags=unknown
356         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
357         do
358
359                 # check if $ARFLAGS already contains this choice
360                 if test "x$ARFLAGS" != "x" ; then
361                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
362                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
363                                 cf_cv_ar_flags=
364                                 break
365                         fi
366                 fi
367
368                 rm -f conftest.$ac_cv_objext
369                 rm -f conftest.a
370
371                 cat >conftest.$ac_ext <<EOF
372 #line __oline__ "configure"
373 int     testdata[[3]] = { 123, 456, 789 };
374 EOF
375                 if AC_TRY_EVAL(ac_compile) ; then
376                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
377                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
378                         if test -f conftest.a ; then
379                                 cf_cv_ar_flags=$cf_ar_flags
380                                 break
381                         fi
382                 else
383                         CF_VERBOSE(cannot compile test-program)
384                         break
385                 fi
386         done
387         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
388 ])
389
390 if test -n "$ARFLAGS" ; then
391         if test -n "$cf_cv_ar_flags" ; then
392                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
393         fi
394 else
395         ARFLAGS=$cf_cv_ar_flags
396 fi
397
398 AC_SUBST(ARFLAGS)
399 ])
400 dnl ---------------------------------------------------------------------------
401 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
402 dnl -----------
403 dnl If we're cross-compiling, allow the user to override the tools and their
404 dnl options.  The configure script is oriented toward identifying the host
405 dnl compiler, etc., but we need a build compiler to generate parts of the
406 dnl source.
407 dnl
408 dnl $1 = default for $CPPFLAGS
409 dnl $2 = default for $LIBS
410 AC_DEFUN([CF_BUILD_CC],[
411 CF_ACVERSION_CHECK(2.52,,
412         [AC_REQUIRE([CF_PROG_EXT])])
413 if test "$cross_compiling" = yes ; then
414
415         # defaults that we might want to override
416         : ${BUILD_CFLAGS:=''}
417         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
418         : ${BUILD_LDFLAGS:=''}
419         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
420         : ${BUILD_EXEEXT:='$x'}
421         : ${BUILD_OBJEXT:='o'}
422
423         AC_ARG_WITH(build-cc,
424                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
425                 [BUILD_CC="$withval"],
426                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
427         AC_MSG_CHECKING(for native build C compiler)
428         AC_MSG_RESULT($BUILD_CC)
429
430         AC_MSG_CHECKING(for native build C preprocessor)
431         AC_ARG_WITH(build-cpp,
432                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
433                 [BUILD_CPP="$withval"],
434                 [BUILD_CPP='${BUILD_CC} -E'])
435         AC_MSG_RESULT($BUILD_CPP)
436
437         AC_MSG_CHECKING(for native build C flags)
438         AC_ARG_WITH(build-cflags,
439                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
440                 [BUILD_CFLAGS="$withval"])
441         AC_MSG_RESULT($BUILD_CFLAGS)
442
443         AC_MSG_CHECKING(for native build C preprocessor-flags)
444         AC_ARG_WITH(build-cppflags,
445                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
446                 [BUILD_CPPFLAGS="$withval"])
447         AC_MSG_RESULT($BUILD_CPPFLAGS)
448
449         AC_MSG_CHECKING(for native build linker-flags)
450         AC_ARG_WITH(build-ldflags,
451                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
452                 [BUILD_LDFLAGS="$withval"])
453         AC_MSG_RESULT($BUILD_LDFLAGS)
454
455         AC_MSG_CHECKING(for native build linker-libraries)
456         AC_ARG_WITH(build-libs,
457                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
458                 [BUILD_LIBS="$withval"])
459         AC_MSG_RESULT($BUILD_LIBS)
460
461         # this assumes we're on Unix.
462         BUILD_EXEEXT=
463         BUILD_OBJEXT=o
464
465         : ${BUILD_CC:='${CC}'}
466
467         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
468                 AC_MSG_ERROR([Cross-build requires two compilers.
469 Use --with-build-cc to specify the native compiler.])
470         fi
471
472 else
473         : ${BUILD_CC:='${CC}'}
474         : ${BUILD_CPP:='${CPP}'}
475         : ${BUILD_CFLAGS:='${CFLAGS}'}
476         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
477         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
478         : ${BUILD_LIBS:='${LIBS}'}
479         : ${BUILD_EXEEXT:='$x'}
480         : ${BUILD_OBJEXT:='o'}
481 fi
482
483 AC_SUBST(BUILD_CC)
484 AC_SUBST(BUILD_CPP)
485 AC_SUBST(BUILD_CFLAGS)
486 AC_SUBST(BUILD_CPPFLAGS)
487 AC_SUBST(BUILD_LDFLAGS)
488 AC_SUBST(BUILD_LIBS)
489 AC_SUBST(BUILD_EXEEXT)
490 AC_SUBST(BUILD_OBJEXT)
491 ])dnl
492 dnl ---------------------------------------------------------------------------
493 dnl CF_CC_ENV_FLAGS version: 1 updated: 2012/10/03 05:25:49
494 dnl ---------------
495 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
496 dnl into CC.  This will not help with broken scripts that wrap the compiler with
497 dnl options, but eliminates a more common category of user confusion.
498 AC_DEFUN([CF_CC_ENV_FLAGS],
499 [
500 # This should have been defined by AC_PROG_CC
501 : ${CC:=cc}
502
503 AC_MSG_CHECKING(\$CC variable)
504 case "$CC" in #(vi
505 *[[\ \  ]]-[[IUD]]*)
506         AC_MSG_RESULT(broken)
507         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
508         # humor him...
509         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
510         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
511         CF_ADD_CFLAGS($cf_flags)
512         ;;
513 *)
514         AC_MSG_RESULT(ok)
515         ;;
516 esac
517 ])dnl
518 dnl ---------------------------------------------------------------------------
519 dnl CF_CFG_DEFAULTS version: 10 updated: 2013/09/07 13:54:05
520 dnl ---------------
521 dnl Determine the default configuration into which we'll install ncurses.  This
522 dnl can be overridden by the user's command-line options.  There's two items to
523 dnl look for:
524 dnl     1. the prefix (e.g., /usr)
525 dnl     2. the header files (e.g., /usr/include/ncurses)
526 dnl We'll look for a previous installation of ncurses and use the same defaults.
527 dnl
528 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
529 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
530 dnl programs from a vendor's.
531 AC_DEFUN([CF_CFG_DEFAULTS],
532 [
533 AC_MSG_CHECKING(for prefix)
534 if test "x$prefix" = "xNONE" ; then
535         case "$cf_cv_system_name" in
536                 # non-vendor systems don't have a conflict
537         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
538                 prefix=/usr
539                 ;;
540         *)      prefix=$ac_default_prefix
541                 ;;
542         esac
543 fi
544 AC_MSG_RESULT($prefix)
545
546 if test "x$prefix" = "xNONE" ; then
547 AC_MSG_CHECKING(for default include-directory)
548 test -n "$verbose" && echo 1>&AC_FD_MSG
549 for cf_symbol in \
550         $includedir \
551         $includedir/ncurses \
552         $prefix/include \
553         $prefix/include/ncurses \
554         /usr/local/include \
555         /usr/local/include/ncurses \
556         /usr/include \
557         /usr/include/ncurses
558 do
559         cf_dir=`eval echo $cf_symbol`
560         if test -f $cf_dir/curses.h ; then
561         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
562                 includedir="$cf_symbol"
563                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
564                 break
565         fi
566         fi
567         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
568 done
569 AC_MSG_RESULT($includedir)
570 fi
571 ])dnl
572 dnl ---------------------------------------------------------------------------
573 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
574 dnl --------------
575 dnl Check if we're accidentally using a cache from a different machine.
576 dnl Derive the system name, as a check for reusing the autoconf cache.
577 dnl
578 dnl If we've packaged config.guess and config.sub, run that (since it does a
579 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
580 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
581 dnl which is useful in cross-compiles.
582 dnl
583 dnl Note: we would use $ac_config_sub, but that is one of the places where
584 dnl autoconf 2.5x broke compatibility with autoconf 2.13
585 AC_DEFUN([CF_CHECK_CACHE],
586 [
587 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
588         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
589         system_name="$host_os"
590 else
591         system_name="`(uname -s -r) 2>/dev/null`"
592         if test -z "$system_name" ; then
593                 system_name="`(hostname) 2>/dev/null`"
594         fi
595 fi
596 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
597 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
598
599 test -z "$system_name" && system_name="$cf_cv_system_name"
600 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
601
602 if test ".$system_name" != ".$cf_cv_system_name" ; then
603         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
604         AC_MSG_ERROR("Please remove config.cache and try again.")
605 fi
606 ])dnl
607 dnl ---------------------------------------------------------------------------
608 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
609 dnl -----------------
610 dnl Check if the given compiler is really clang.  clang's C driver defines
611 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
612 dnl not ignore some gcc options.
613 dnl
614 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
615 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
616 dnl the wrappers for gcc and g++ warnings.
617 dnl
618 dnl $1 = GCC (default) or GXX
619 dnl $2 = CLANG_COMPILER (default)
620 dnl $3 = CFLAGS (default) or CXXFLAGS
621 AC_DEFUN([CF_CLANG_COMPILER],[
622 ifelse([$2],,CLANG_COMPILER,[$2])=no
623
624 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
625         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
626         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
627         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
628         AC_TRY_COMPILE([],[
629 #ifdef __clang__
630 #else
631 make an error
632 #endif
633 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
634 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
635 ],[])
636         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
637         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
638 fi
639 ])
640 dnl ---------------------------------------------------------------------------
641 dnl CF_CURSES_HEADER version: 3 updated: 2011/05/01 19:47:45
642 dnl ----------------
643 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
644 dnl variations of ncurses' installs.
645 dnl
646 dnl $1 = ncurses when looking for ncurses, or is empty
647 AC_DEFUN([CF_CURSES_HEADER],[
648 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
649 cf_cv_ncurses_header=none
650 for cf_header in ifelse($1,,,[ \
651     $1/ncurses.h \
652         $1/curses.h]) \
653         ncurses.h \
654         curses.h ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
655 do
656 AC_TRY_COMPILE([#include <${cf_header}>],
657         [initscr(); tgoto("?", 0,0)],
658         [cf_cv_ncurses_header=$cf_header; break],[])
659 done
660 ])
661
662 if test "$cf_cv_ncurses_header" = none ; then
663         AC_MSG_ERROR(No curses header-files found)
664 fi
665
666 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
667 AC_CHECK_HEADERS($cf_cv_ncurses_header)
668 ])dnl
669 dnl ---------------------------------------------------------------------------
670 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
671 dnl ----------
672 dnl "dirname" is not portable, so we fake it with a shell script.
673 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
674 dnl ---------------------------------------------------------------------------
675 dnl CF_DISABLE_ECHO version: 12 updated: 2012/10/06 16:30:28
676 dnl ---------------
677 dnl You can always use "make -n" to see the actual options, but it's hard to
678 dnl pick out/analyze warning messages when the compile-line is long.
679 dnl
680 dnl Sets:
681 dnl     ECHO_LT - symbol to control if libtool is verbose
682 dnl     ECHO_LD - symbol to prefix "cc -o" lines
683 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
684 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
685 dnl     ECHO_CC - symbol to put before any "cc" line
686 dnl
687 AC_DEFUN([CF_DISABLE_ECHO],[
688 AC_MSG_CHECKING(if you want to see long compiling messages)
689 CF_ARG_DISABLE(echo,
690         [  --disable-echo          do not display "compiling" commands],
691         [
692     ECHO_LT='--silent'
693     ECHO_LD='@echo linking [$]@;'
694     RULE_CC='@echo compiling [$]<'
695     SHOW_CC='@echo compiling [$]@'
696     ECHO_CC='@'
697 ],[
698     ECHO_LT=''
699     ECHO_LD=''
700     RULE_CC=''
701     SHOW_CC=''
702     ECHO_CC=''
703 ])
704 AC_MSG_RESULT($enableval)
705 AC_SUBST(ECHO_LT)
706 AC_SUBST(ECHO_LD)
707 AC_SUBST(RULE_CC)
708 AC_SUBST(SHOW_CC)
709 AC_SUBST(ECHO_CC)
710 ])dnl
711 dnl ---------------------------------------------------------------------------
712 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
713 dnl ------------------------
714 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
715 AC_MSG_CHECKING(if we want to use GNAT projects)
716 CF_ARG_DISABLE(gnat-projects,
717         [  --disable-gnat-projects test: disable GNAT projects even if usable],
718         [enable_gnat_projects=no],
719         [enable_gnat_projects=yes])
720 AC_MSG_RESULT($enable_gnat_projects)
721 ])dnl
722 dnl ---------------------------------------------------------------------------
723 dnl CF_ENABLE_PC_FILES version: 9 updated: 2012/08/04 13:59:54
724 dnl ------------------
725 dnl This is the "--enable-pc-files" option, which is available if there is a
726 dnl pkg-config configuration on the local machine.
727 AC_DEFUN([CF_ENABLE_PC_FILES],[
728 AC_REQUIRE([CF_PKG_CONFIG])
729 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
730
731 if test "$PKG_CONFIG" != none ; then
732         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
733         AC_ARG_ENABLE(pc-files,
734                 [  --enable-pc-files       generate and install .pc files for pkg-config],
735                 [enable_pc_files=$enableval],
736                 [enable_pc_files=no])
737         AC_MSG_RESULT($enable_pc_files)
738         if test "$enable_pc_files" != no
739         then
740                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
741         fi
742 else
743         enable_pc_files=no
744 fi
745 ])dnl
746 dnl ---------------------------------------------------------------------------
747 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
748 dnl ---------------
749 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
750 dnl prefer a standard location, and use -L options only if we do not find the
751 dnl library in the standard library location(s).
752 dnl     $1 = library name
753 dnl     $2 = library class, usually the same as library name
754 dnl     $3 = includes
755 dnl     $4 = code fragment to compile/link
756 dnl     $5 = corresponding function-name
757 dnl     $6 = flag, nonnull if failure should not cause an error-exit
758 dnl
759 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
760 dnl to use a -L option.
761 AC_DEFUN([CF_FIND_LIBRARY],
762 [
763         eval 'cf_cv_have_lib_'$1'=no'
764         cf_libdir=""
765         AC_CHECK_FUNC($5,
766                 eval 'cf_cv_have_lib_'$1'=yes',[
767                 cf_save_LIBS="$LIBS"
768                 AC_MSG_CHECKING(for $5 in -l$1)
769                 LIBS="-l$1 $LIBS"
770                 AC_TRY_LINK([$3],[$4],
771                         [AC_MSG_RESULT(yes)
772                          eval 'cf_cv_have_lib_'$1'=yes'
773                         ],
774                         [AC_MSG_RESULT(no)
775                         CF_LIBRARY_PATH(cf_search,$2)
776                         for cf_libdir in $cf_search
777                         do
778                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
779                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
780                                 AC_TRY_LINK([$3],[$4],
781                                         [AC_MSG_RESULT(yes)
782                                          eval 'cf_cv_have_lib_'$1'=yes'
783                                          break],
784                                         [AC_MSG_RESULT(no)
785                                          LIBS="$cf_save_LIBS"])
786                         done
787                         ])
788                 ])
789 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
790 ifelse($6,,[
791 if test $cf_found_library = no ; then
792         AC_MSG_ERROR(Cannot link $1 library)
793 fi
794 ])
795 ])dnl
796 dnl ---------------------------------------------------------------------------
797 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
798 dnl ---------------
799 dnl Find a library (specifically the linkage used in the code fragment),
800 dnl searching for it if it is not already in the library path.
801 dnl See also CF_ADD_SEARCHPATH.
802 dnl
803 dnl Parameters (4-on are optional):
804 dnl     $1 = headers for library entrypoint
805 dnl     $2 = code fragment for library entrypoint
806 dnl     $3 = the library name without the "-l" option or ".so" suffix.
807 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
808 dnl     $5 = action to perform if not successful
809 dnl     $6 = module name, if not the same as the library name
810 dnl     $7 = extra libraries
811 dnl
812 dnl Sets these variables:
813 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
814 dnl     $cf_cv_header_path_$3 - include-directory if needed
815 dnl     $cf_cv_library_path_$3 - library-directory if needed
816 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
817 AC_DEFUN([CF_FIND_LINKAGE],[
818
819 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
820 # will be set on completion of the AC_TRY_LINK below.
821 cf_cv_header_path_$3=
822 cf_cv_library_path_$3=
823
824 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
825
826 cf_save_LIBS="$LIBS"
827
828 AC_TRY_LINK([$1],[$2],[
829         cf_cv_find_linkage_$3=yes
830         cf_cv_header_path_$3=/usr/include
831         cf_cv_library_path_$3=/usr/lib
832 ],[
833
834 LIBS="-l$3 $7 $cf_save_LIBS"
835
836 AC_TRY_LINK([$1],[$2],[
837         cf_cv_find_linkage_$3=yes
838         cf_cv_header_path_$3=/usr/include
839         cf_cv_library_path_$3=/usr/lib
840         cf_cv_library_file_$3="-l$3"
841 ],[
842         cf_cv_find_linkage_$3=no
843         LIBS="$cf_save_LIBS"
844
845     CF_VERBOSE(find linkage for $3 library)
846     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
847
848     cf_save_CPPFLAGS="$CPPFLAGS"
849     cf_test_CPPFLAGS="$CPPFLAGS"
850
851     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
852     for cf_cv_header_path_$3 in $cf_search
853     do
854       if test -d $cf_cv_header_path_$3 ; then
855         CF_VERBOSE(... testing $cf_cv_header_path_$3)
856         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
857         AC_TRY_COMPILE([$1],[$2],[
858             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
859             cf_cv_find_linkage_$3=maybe
860             cf_test_CPPFLAGS="$CPPFLAGS"
861             break],[
862             CPPFLAGS="$cf_save_CPPFLAGS"
863             ])
864       fi
865     done
866
867     if test "$cf_cv_find_linkage_$3" = maybe ; then
868
869       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
870
871       cf_save_LIBS="$LIBS"
872       cf_save_LDFLAGS="$LDFLAGS"
873
874       ifelse([$6],,,[
875         CPPFLAGS="$cf_test_CPPFLAGS"
876         LIBS="-l$3 $7 $cf_save_LIBS"
877         AC_TRY_LINK([$1],[$2],[
878             CF_VERBOSE(... found $3 library in system)
879             cf_cv_find_linkage_$3=yes])
880             CPPFLAGS="$cf_save_CPPFLAGS"
881             LIBS="$cf_save_LIBS"
882             ])
883
884       if test "$cf_cv_find_linkage_$3" != yes ; then
885         CF_LIBRARY_PATH(cf_search,$3)
886         for cf_cv_library_path_$3 in $cf_search
887         do
888           if test -d $cf_cv_library_path_$3 ; then
889             CF_VERBOSE(... testing $cf_cv_library_path_$3)
890             CPPFLAGS="$cf_test_CPPFLAGS"
891             LIBS="-l$3 $7 $cf_save_LIBS"
892             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
893             AC_TRY_LINK([$1],[$2],[
894                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
895                 cf_cv_find_linkage_$3=yes
896                 cf_cv_library_file_$3="-l$3"
897                 break],[
898                 CPPFLAGS="$cf_save_CPPFLAGS"
899                 LIBS="$cf_save_LIBS"
900                 LDFLAGS="$cf_save_LDFLAGS"
901                 ])
902           fi
903         done
904         CPPFLAGS="$cf_save_CPPFLAGS"
905         LDFLAGS="$cf_save_LDFLAGS"
906       fi
907
908     else
909       cf_cv_find_linkage_$3=no
910     fi
911     ],$7)
912 ])
913
914 LIBS="$cf_save_LIBS"
915
916 if test "$cf_cv_find_linkage_$3" = yes ; then
917 ifelse([$4],,[
918         CF_ADD_INCDIR($cf_cv_header_path_$3)
919         CF_ADD_LIBDIR($cf_cv_library_path_$3)
920         CF_ADD_LIB($3)
921 ],[$4])
922 else
923 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
924 fi
925 ])dnl
926 dnl ---------------------------------------------------------------------------
927 dnl CF_FIXUP_ADAFLAGS version: 1 updated: 2012/03/31 18:48:10
928 dnl -----------------
929 dnl make ADAFLAGS consistent with CFLAGS
930 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
931         AC_MSG_CHECKING(optimization options for ADAFLAGS)
932         case "$CFLAGS" in
933         *-g*)
934                 CF_ADD_ADAFLAGS(-g)
935                 ;;
936         esac
937         case "$CFLAGS" in
938         *-O*)
939                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
940                 CF_ADD_ADAFLAGS($cf_O_flag)
941                 ;;
942         esac
943         AC_MSG_RESULT($ADAFLAGS)
944 ])dnl
945 dnl ---------------------------------------------------------------------------
946 dnl CF_GCC_ATTRIBUTES version: 16 updated: 2012/10/02 20:55:03
947 dnl -----------------
948 dnl Test for availability of useful gcc __attribute__ directives to quiet
949 dnl compiler warnings.  Though useful, not all are supported -- and contrary
950 dnl to documentation, unrecognized directives cause older compilers to barf.
951 AC_DEFUN([CF_GCC_ATTRIBUTES],
952 [
953 if test "$GCC" = yes
954 then
955 cat > conftest.i <<EOF
956 #ifndef GCC_PRINTF
957 #define GCC_PRINTF 0
958 #endif
959 #ifndef GCC_SCANF
960 #define GCC_SCANF 0
961 #endif
962 #ifndef GCC_NORETURN
963 #define GCC_NORETURN /* nothing */
964 #endif
965 #ifndef GCC_UNUSED
966 #define GCC_UNUSED /* nothing */
967 #endif
968 EOF
969 if test "$GCC" = yes
970 then
971         AC_CHECKING([for $CC __attribute__ directives])
972 cat > conftest.$ac_ext <<EOF
973 #line __oline__ "${as_me:-configure}"
974 #include "confdefs.h"
975 #include "conftest.h"
976 #include "conftest.i"
977 #if     GCC_PRINTF
978 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
979 #else
980 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
981 #endif
982 #if     GCC_SCANF
983 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
984 #else
985 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
986 #endif
987 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
988 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
989 extern void foo(void) GCC_NORETURN;
990 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
991 EOF
992         cf_printf_attribute=no
993         cf_scanf_attribute=no
994         for cf_attribute in scanf printf unused noreturn
995         do
996                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
997                 cf_directive="__attribute__(($cf_attribute))"
998                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
999
1000                 case $cf_attribute in #(vi
1001                 printf) #(vi
1002                         cf_printf_attribute=yes
1003                         cat >conftest.h <<EOF
1004 #define GCC_$cf_ATTRIBUTE 1
1005 EOF
1006                         ;;
1007                 scanf) #(vi
1008                         cf_scanf_attribute=yes
1009                         cat >conftest.h <<EOF
1010 #define GCC_$cf_ATTRIBUTE 1
1011 EOF
1012                         ;;
1013                 *) #(vi
1014                         cat >conftest.h <<EOF
1015 #define GCC_$cf_ATTRIBUTE $cf_directive
1016 EOF
1017                         ;;
1018                 esac
1019
1020                 if AC_TRY_EVAL(ac_compile); then
1021                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1022                         cat conftest.h >>confdefs.h
1023                         case $cf_attribute in #(vi
1024                         noreturn) #(vi
1025                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1026                                 ;;
1027                         printf) #(vi
1028                                 cf_value='/* nothing */'
1029                                 if test "$cf_printf_attribute" != no ; then
1030                                         cf_value='__attribute__((format(printf,fmt,var)))'
1031                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1032                                 fi
1033                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1034                                 ;;
1035                         scanf) #(vi
1036                                 cf_value='/* nothing */'
1037                                 if test "$cf_scanf_attribute" != no ; then
1038                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1039                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1040                                 fi
1041                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1042                                 ;;
1043                         unused) #(vi
1044                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1045                                 ;;
1046                         esac
1047                 fi
1048         done
1049 else
1050         fgrep define conftest.i >>confdefs.h
1051 fi
1052 rm -rf conftest*
1053 fi
1054 ])dnl
1055 dnl ---------------------------------------------------------------------------
1056 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1057 dnl --------------
1058 dnl Find version of gcc
1059 AC_DEFUN([CF_GCC_VERSION],[
1060 AC_REQUIRE([AC_PROG_CC])
1061 GCC_VERSION=none
1062 if test "$GCC" = yes ; then
1063         AC_MSG_CHECKING(version of $CC)
1064         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1065         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1066         AC_MSG_RESULT($GCC_VERSION)
1067 fi
1068 ])dnl
1069 dnl ---------------------------------------------------------------------------
1070 dnl CF_GCC_WARNINGS version: 31 updated: 2013/11/19 19:23:35
1071 dnl ---------------
1072 dnl Check if the compiler supports useful warning options.  There's a few that
1073 dnl we don't use, simply because they're too noisy:
1074 dnl
1075 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1076 dnl     -Wredundant-decls (system headers make this too noisy)
1077 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1078 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1079 dnl             is enabled for ncurses using "--enable-const".
1080 dnl     -pedantic
1081 dnl
1082 dnl Parameter:
1083 dnl     $1 is an optional list of gcc warning flags that a particular
1084 dnl             application might want to use, e.g., "no-unused" for
1085 dnl             -Wno-unused
1086 dnl Special:
1087 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1088 dnl
1089 AC_DEFUN([CF_GCC_WARNINGS],
1090 [
1091 AC_REQUIRE([CF_GCC_VERSION])
1092 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1093 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1094
1095 cat > conftest.$ac_ext <<EOF
1096 #line __oline__ "${as_me:-configure}"
1097 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1098 EOF
1099
1100 if test "$INTEL_COMPILER" = yes
1101 then
1102 # The "-wdXXX" options suppress warnings:
1103 # remark #1419: external declaration in primary source file
1104 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1105 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1106 # remark #193: zero used for undefined preprocessing identifier
1107 # remark #593: variable "curs_sb_left_arrow" was set but never used
1108 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1109 # remark #869: parameter "tw" was never referenced
1110 # remark #981: operands are evaluated in unspecified order
1111 # warning #279: controlling expression is constant
1112
1113         AC_CHECKING([for $CC warning options])
1114         cf_save_CFLAGS="$CFLAGS"
1115         EXTRA_CFLAGS="-Wall"
1116         for cf_opt in \
1117                 wd1419 \
1118                 wd1683 \
1119                 wd1684 \
1120                 wd193 \
1121                 wd593 \
1122                 wd279 \
1123                 wd810 \
1124                 wd869 \
1125                 wd981
1126         do
1127                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1128                 if AC_TRY_EVAL(ac_compile); then
1129                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1130                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1131                 fi
1132         done
1133         CFLAGS="$cf_save_CFLAGS"
1134
1135 elif test "$GCC" = yes
1136 then
1137         AC_CHECKING([for $CC warning options])
1138         cf_save_CFLAGS="$CFLAGS"
1139         EXTRA_CFLAGS=
1140         cf_warn_CONST=""
1141         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1142         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1143         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1144         for cf_opt in W Wall \
1145                 Wbad-function-cast \
1146                 Wcast-align \
1147                 Wcast-qual \
1148                 Wdeclaration-after-statement \
1149                 Wextra \
1150                 Winline \
1151                 Wmissing-declarations \
1152                 Wmissing-prototypes \
1153                 Wnested-externs \
1154                 Wpointer-arith \
1155                 Wshadow \
1156                 Wstrict-prototypes \
1157                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
1158         do
1159                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1160                 if AC_TRY_EVAL(ac_compile); then
1161                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1162                         case $cf_opt in #(vi
1163                         Wcast-qual) #(vi
1164                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1165                                 ;;
1166                         Winline) #(vi
1167                                 case $GCC_VERSION in
1168                                 [[34]].*)
1169                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1170                                         continue;;
1171                                 esac
1172                                 ;;
1173                         Wpointer-arith) #(vi
1174                                 case $GCC_VERSION in
1175                                 [[12]].*)
1176                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1177                                         continue;;
1178                                 esac
1179                                 ;;
1180                         esac
1181                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1182                 fi
1183         done
1184         CFLAGS="$cf_save_CFLAGS"
1185 fi
1186 rm -rf conftest*
1187
1188 AC_SUBST(EXTRA_CFLAGS)
1189 ])dnl
1190 dnl ---------------------------------------------------------------------------
1191 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
1192 dnl ----------------
1193 AC_DEFUN([CF_GNAT_GENERICS],
1194 [
1195 AC_REQUIRE([CF_GNAT_VERSION])
1196
1197 AC_MSG_CHECKING(if GNAT supports generics)
1198 case $cf_gnat_version in #(vi
1199 3.[[1-9]]*|[[4-9]].*) #(vi
1200         cf_gnat_generics=yes
1201         ;;
1202 *)
1203         cf_gnat_generics=no
1204         ;;
1205 esac
1206 AC_MSG_RESULT($cf_gnat_generics)
1207
1208 if test "$cf_gnat_generics" = yes
1209 then
1210         cf_compile_generics=generics
1211         cf_generic_objects="\${GENOBJS}"
1212 else
1213         cf_compile_generics=
1214         cf_generic_objects=
1215 fi
1216
1217 AC_SUBST(cf_compile_generics)
1218 AC_SUBST(cf_generic_objects)
1219 ])dnl
1220 dnl ---------------------------------------------------------------------------
1221 dnl CF_GNAT_PROJECTS version: 7 updated: 2014/06/01 10:46:34
1222 dnl ----------------
1223 dnl GNAT projects are configured with ".gpr" project files.
1224 dnl GNAT libraries are a further development, using the project feature.
1225 AC_DEFUN([CF_GNAT_PROJECTS],
1226 [
1227 AC_REQUIRE([CF_GNAT_VERSION])
1228 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
1229
1230 cf_gnat_libraries=no
1231 cf_gnat_projects=no
1232
1233 if test "$enable_gnat_projects" != no ; then
1234 AC_MSG_CHECKING(if GNAT supports project files)
1235 case $cf_gnat_version in #(vi
1236 3.[[0-9]]*) #(vi
1237         ;;
1238 *)
1239         case $cf_cv_system_name in #(vi
1240         cygwin*|msys*) #(vi
1241                 ;;
1242         *)
1243                 mkdir conftest.src conftest.bin conftest.lib
1244                 cd conftest.src
1245                 rm -rf conftest* *~conftest*
1246                 cat >>library.gpr <<CF_EOF
1247 project Library is
1248   Kind := External ("LIB_KIND");
1249   for Library_Name use "ConfTest";
1250   for Object_Dir use ".";
1251   for Library_ALI_Dir use External("LIBRARY_DIR");
1252   for Library_Version use External ("SONAME");
1253   for Library_Kind use Kind;
1254   for Library_Dir use External("BUILD_DIR");
1255   Source_Dir := External ("SOURCE_DIR");
1256   for Source_Dirs use (Source_Dir);
1257 end Library;
1258 CF_EOF
1259                 cat >>confpackage.ads <<CF_EOF
1260 package ConfPackage is
1261    procedure conftest;
1262 end ConfPackage;
1263 CF_EOF
1264                 cat >>confpackage.adb <<CF_EOF
1265 with Text_IO;
1266 package body ConfPackage is
1267    procedure conftest is
1268    begin
1269       Text_IO.Put ("Hello World");
1270       Text_IO.New_Line;
1271    end conftest;
1272 end ConfPackage;
1273 CF_EOF
1274                 if ( $cf_ada_make $ADAFLAGS \
1275                                 -Plibrary.gpr \
1276                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
1277                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
1278                                 -XSOURCE_DIR=`pwd` \
1279                                 -XSONAME=libConfTest.so.1 \
1280                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
1281                         cf_gnat_projects=yes
1282                 fi
1283                 cd ..
1284                 if test -f conftest.lib/confpackage.ali
1285                 then
1286                         cf_gnat_libraries=yes
1287                 fi
1288                 rm -rf conftest* *~conftest*
1289                 ;;
1290         esac
1291         ;;
1292 esac
1293 AC_MSG_RESULT($cf_gnat_projects)
1294 fi # enable_gnat_projects
1295
1296 if test $cf_gnat_projects = yes
1297 then
1298         AC_MSG_CHECKING(if GNAT supports libraries)
1299         AC_MSG_RESULT($cf_gnat_libraries)
1300 fi
1301
1302 if test "$cf_gnat_projects" = yes
1303 then
1304         USE_OLD_MAKERULES="#"
1305         USE_GNAT_PROJECTS=""
1306 else
1307         USE_OLD_MAKERULES=""
1308         USE_GNAT_PROJECTS="#"
1309 fi
1310
1311 if test "$cf_gnat_libraries" = yes
1312 then
1313         USE_GNAT_LIBRARIES=""
1314 else
1315         USE_GNAT_LIBRARIES="#"
1316 fi
1317
1318 AC_SUBST(USE_OLD_MAKERULES)
1319 AC_SUBST(USE_GNAT_PROJECTS)
1320 AC_SUBST(USE_GNAT_LIBRARIES)
1321 ])dnl
1322 dnl ---------------------------------------------------------------------------
1323 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
1324 dnl --------------
1325 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
1326 dnl is noted that gnat may compile a tasking unit even for configurations which
1327 dnl fail at runtime.
1328 AC_DEFUN([CF_GNAT_SIGINT],[
1329 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
1330 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
1331
1332 package ConfTest is
1333
1334    pragma Warnings (Off);  --  the next pragma exists since 3.11p
1335    pragma Unreserve_All_Interrupts;
1336    pragma Warnings (On);
1337
1338    protected Process is
1339       procedure Stop;
1340       function Continue return Boolean;
1341       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
1342    private
1343       Done : Boolean := False;
1344    end Process;
1345
1346 end ConfTest;],
1347 [package body ConfTest is
1348    protected body Process is
1349       procedure Stop is
1350       begin
1351          Done := True;
1352       end Stop;
1353       function Continue return Boolean is
1354       begin
1355          return not Done;
1356       end Continue;
1357    end Process;
1358 end ConfTest;],
1359         [cf_cv_gnat_sigint=yes],
1360         [cf_cv_gnat_sigint=no])])
1361
1362 if test $cf_cv_gnat_sigint = yes ; then
1363         USE_GNAT_SIGINT=""
1364 else
1365         USE_GNAT_SIGINT="#"
1366 fi
1367 AC_SUBST(USE_GNAT_SIGINT)
1368 ])dnl
1369 dnl ---------------------------------------------------------------------------
1370 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
1371 dnl ----------------
1372 dnl Verify that a test program compiles/links with GNAT.
1373 dnl $cf_ada_make is set to the program that compiles/links
1374 dnl $ADAFLAGS may be set to the GNAT flags.
1375 dnl
1376 dnl $1 is the text of the spec
1377 dnl $2 is the text of the body
1378 dnl $3 is the shell command to execute if successful
1379 dnl $4 is the shell command to execute if not successful
1380 AC_DEFUN([CF_GNAT_TRY_LINK],
1381 [
1382 rm -rf conftest* *~conftest*
1383 cat >>conftest.ads <<CF_EOF
1384 $1
1385 CF_EOF
1386 cat >>conftest.adb <<CF_EOF
1387 $2
1388 CF_EOF
1389 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1390 ifelse($3,,      :,[      $3])
1391 ifelse($4,,,[else
1392    $4])
1393 fi
1394 rm -rf conftest* *~conftest*
1395 ])dnl
1396 dnl ---------------------------------------------------------------------------
1397 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
1398 dnl ---------------
1399 dnl Verify that a test program compiles and runs with GNAT
1400 dnl $cf_ada_make is set to the program that compiles/links
1401 dnl $ADAFLAGS may be set to the GNAT flags.
1402 dnl
1403 dnl $1 is the text of the spec
1404 dnl $2 is the text of the body
1405 dnl $3 is the shell command to execute if successful
1406 dnl $4 is the shell command to execute if not successful
1407 AC_DEFUN([CF_GNAT_TRY_RUN],
1408 [
1409 rm -rf conftest* *~conftest*
1410 cat >>conftest.ads <<CF_EOF
1411 $1
1412 CF_EOF
1413 cat >>conftest.adb <<CF_EOF
1414 $2
1415 CF_EOF
1416 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1417    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1418 ifelse($3,,      :,[      $3])
1419 ifelse($4,,,[   else
1420       $4])
1421    fi
1422 ifelse($4,,,[else
1423    $4])
1424 fi
1425 rm -rf conftest* *~conftest*
1426 ])dnl
1427 dnl ---------------------------------------------------------------------------
1428 dnl CF_GNAT_VERSION version: 18 updated: 2012/01/21 19:28:10
1429 dnl ---------------
1430 dnl Verify version of GNAT.
1431 AC_DEFUN([CF_GNAT_VERSION],
1432 [
1433 AC_MSG_CHECKING(for gnat version)
1434 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
1435         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1436     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1437 AC_MSG_RESULT($cf_gnat_version)
1438
1439 case $cf_gnat_version in #(vi
1440 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]]) #(vi
1441         cf_cv_prog_gnat_correct=yes
1442         ;;
1443 *)
1444         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1445         cf_cv_prog_gnat_correct=no
1446         ;;
1447 esac
1448 ])
1449 dnl ---------------------------------------------------------------------------
1450 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
1451 dnl -------------
1452 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1453 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1454 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1455 dnl since it is interwoven with GNU extensions.
1456 dnl
1457 dnl Well, yes we could work around it...
1458 AC_DEFUN([CF_GNU_SOURCE],
1459 [
1460 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1461 AC_TRY_COMPILE([#include <sys/types.h>],[
1462 #ifndef _XOPEN_SOURCE
1463 make an error
1464 #endif],
1465         [cf_cv_gnu_source=no],
1466         [cf_save="$CPPFLAGS"
1467          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1468          AC_TRY_COMPILE([#include <sys/types.h>],[
1469 #ifdef _XOPEN_SOURCE
1470 make an error
1471 #endif],
1472         [cf_cv_gnu_source=no],
1473         [cf_cv_gnu_source=yes])
1474         CPPFLAGS="$cf_save"
1475         ])
1476 ])
1477 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1478 ])dnl
1479 dnl ---------------------------------------------------------------------------
1480 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
1481 dnl --------------
1482 dnl Construct a search-list of directories for a nonstandard header-file
1483 dnl
1484 dnl Parameters
1485 dnl     $1 = the variable to return as result
1486 dnl     $2 = the package name
1487 AC_DEFUN([CF_HEADER_PATH],
1488 [
1489 $1=
1490
1491 # collect the current set of include-directories from compiler flags
1492 cf_header_path_list=""
1493 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1494         for cf_header_path in $CPPFLAGS $CFLAGS
1495         do
1496                 case $cf_header_path in #(vi
1497                 -I*)
1498                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1499                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1500                         cf_header_path_list="$cf_header_path_list [$]$1"
1501                         ;;
1502                 esac
1503         done
1504 fi
1505
1506 # add the variations for the package we are looking for
1507 CF_SUBDIR_PATH($1,$2,include)
1508
1509 test "$includedir" != NONE && \
1510 test "$includedir" != "/usr/include" && \
1511 test -d "$includedir" && {
1512         test -d $includedir &&    $1="[$]$1 $includedir"
1513         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1514 }
1515
1516 test "$oldincludedir" != NONE && \
1517 test "$oldincludedir" != "/usr/include" && \
1518 test -d "$oldincludedir" && {
1519         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1520         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1521 }
1522
1523 $1="[$]$1 $cf_header_path_list"
1524 ])dnl
1525 dnl ---------------------------------------------------------------------------
1526 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
1527 dnl ---------------
1528 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1529 AC_DEFUN([CF_HELP_MESSAGE],
1530 [AC_DIVERT_HELP([$1])dnl
1531 ])dnl
1532 dnl ---------------------------------------------------------------------------
1533 dnl CF_INCLUDE_DIRS version: 8 updated: 2013/10/12 16:45:09
1534 dnl ---------------
1535 dnl Construct the list of include-options according to whether we're building
1536 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
1537 dnl with gcc, don't append the includedir if it happens to be /usr/include,
1538 dnl since that usually breaks gcc's shadow-includes.
1539 AC_DEFUN([CF_INCLUDE_DIRS],
1540 [
1541 if test "$GCC" != yes; then
1542         CPPFLAGS="-I\${includedir} $CPPFLAGS"
1543 elif test "$includedir" != "/usr/include"; then
1544         if test "$includedir" = '${prefix}/include' ; then
1545                 if test x$prefix != x/usr ; then
1546                         CPPFLAGS="-I\${includedir} $CPPFLAGS"
1547                 fi
1548         else
1549                 CPPFLAGS="-I\${includedir} $CPPFLAGS"
1550         fi
1551 fi
1552 if test "$srcdir" != "."; then
1553         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
1554 fi
1555 CPPFLAGS="-I. -I../include $CPPFLAGS"
1556 AC_SUBST(CPPFLAGS)
1557 ])dnl
1558 dnl ---------------------------------------------------------------------------
1559 dnl CF_INTEL_COMPILER version: 6 updated: 2014/03/17 13:13:07
1560 dnl -----------------
1561 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1562 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1563 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1564 dnl
1565 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1566 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1567 dnl the wrappers for gcc and g++ warnings.
1568 dnl
1569 dnl $1 = GCC (default) or GXX
1570 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1571 dnl $3 = CFLAGS (default) or CXXFLAGS
1572 AC_DEFUN([CF_INTEL_COMPILER],[
1573 AC_REQUIRE([AC_CANONICAL_HOST])
1574 ifelse([$2],,INTEL_COMPILER,[$2])=no
1575
1576 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1577         case $host_os in
1578         linux*|gnu*)
1579                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1580                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1581                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1582                 AC_TRY_COMPILE([],[
1583 #ifdef __INTEL_COMPILER
1584 #else
1585 make an error
1586 #endif
1587 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1588 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
1589 ],[])
1590                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1591                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1592                 ;;
1593         esac
1594 fi
1595 ])dnl
1596 dnl ---------------------------------------------------------------------------
1597 dnl CF_LARGEFILE version: 8 updated: 2012/10/06 08:57:51
1598 dnl ------------
1599 dnl Add checks for large file support.
1600 AC_DEFUN([CF_LARGEFILE],[
1601 ifdef([AC_FUNC_FSEEKO],[
1602     AC_SYS_LARGEFILE
1603     if test "$enable_largefile" != no ; then
1604         AC_FUNC_FSEEKO
1605
1606         # Normally we would collect these definitions in the config.h,
1607         # but (like _XOPEN_SOURCE), some environments rely on having these
1608         # defined before any of the system headers are included.  Another
1609         # case comes up with C++, e.g., on AIX the compiler compiles the
1610         # header files by themselves before looking at the body files it is
1611         # told to compile.  For ncurses, those header files do not include
1612         # the config.h
1613         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
1614         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
1615         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
1616
1617         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
1618                 AC_TRY_COMPILE([
1619 #include <sys/types.h>
1620 #include <dirent.h>
1621                 ],[
1622                 /* if transitional largefile support is setup, this is true */
1623                 extern struct dirent64 * readdir(DIR *);
1624                 struct dirent64 *x = readdir((DIR *)0);
1625                 struct dirent *y = readdir((DIR *)0);
1626                 int z = x - y;
1627                 ],
1628                 [cf_cv_struct_dirent64=yes],
1629                 [cf_cv_struct_dirent64=no])
1630         ])
1631         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
1632     fi
1633 ])
1634 ])
1635 dnl ---------------------------------------------------------------------------
1636 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
1637 dnl ---------------
1638 dnl For the given system and compiler, find the compiler flags to pass to the
1639 dnl loader to use the "rpath" feature.
1640 AC_DEFUN([CF_LD_RPATH_OPT],
1641 [
1642 AC_REQUIRE([CF_CHECK_CACHE])
1643
1644 LD_RPATH_OPT=
1645 AC_MSG_CHECKING(for an rpath option)
1646 case $cf_cv_system_name in #(vi
1647 irix*) #(vi
1648         if test "$GCC" = yes; then
1649                 LD_RPATH_OPT="-Wl,-rpath,"
1650         else
1651                 LD_RPATH_OPT="-rpath "
1652         fi
1653         ;;
1654 linux*|gnu*|k*bsd*-gnu) #(vi
1655         LD_RPATH_OPT="-Wl,-rpath,"
1656         ;;
1657 openbsd[[2-9]].*|mirbsd*) #(vi
1658         LD_RPATH_OPT="-Wl,-rpath,"
1659         ;;
1660 dragonfly*|freebsd*) #(vi
1661         LD_RPATH_OPT="-rpath "
1662         ;;
1663 netbsd*) #(vi
1664         LD_RPATH_OPT="-Wl,-rpath,"
1665         ;;
1666 osf*|mls+*) #(vi
1667         LD_RPATH_OPT="-rpath "
1668         ;;
1669 solaris2*) #(vi
1670         LD_RPATH_OPT="-R"
1671         ;;
1672 *)
1673         ;;
1674 esac
1675 AC_MSG_RESULT($LD_RPATH_OPT)
1676
1677 case "x$LD_RPATH_OPT" in #(vi
1678 x-R*)
1679         AC_MSG_CHECKING(if we need a space after rpath option)
1680         cf_save_LIBS="$LIBS"
1681         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1682         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1683         LIBS="$cf_save_LIBS"
1684         AC_MSG_RESULT($cf_rpath_space)
1685         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1686         ;;
1687 esac
1688 ])dnl
1689 dnl ---------------------------------------------------------------------------
1690 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
1691 dnl ---------------
1692 dnl Construct a search-list of directories for a nonstandard library-file
1693 dnl
1694 dnl Parameters
1695 dnl     $1 = the variable to return as result
1696 dnl     $2 = the package name
1697 AC_DEFUN([CF_LIBRARY_PATH],
1698 [
1699 $1=
1700 cf_library_path_list=""
1701 if test -n "${LDFLAGS}${LIBS}" ; then
1702         for cf_library_path in $LDFLAGS $LIBS
1703         do
1704                 case $cf_library_path in #(vi
1705                 -L*)
1706                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1707                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1708                         cf_library_path_list="$cf_library_path_list [$]$1"
1709                         ;;
1710                 esac
1711         done
1712 fi
1713
1714 CF_SUBDIR_PATH($1,$2,lib)
1715
1716 $1="$cf_library_path_list [$]$1"
1717 ])dnl
1718 dnl ---------------------------------------------------------------------------
1719 dnl CF_LIB_PREFIX version: 9 updated: 2012/01/21 19:28:10
1720 dnl -------------
1721 dnl Compute the library-prefix for the given host system
1722 dnl $1 = variable to set
1723 define([CF_LIB_PREFIX],
1724 [
1725         case $cf_cv_system_name in #(vi
1726         OS/2*|os2*) #(vi
1727         LIB_PREFIX=''
1728         ;;
1729         *)      LIB_PREFIX='lib'
1730         ;;
1731         esac
1732 ifelse($1,,,[$1=$LIB_PREFIX])
1733         AC_SUBST(LIB_PREFIX)
1734 ])dnl
1735 dnl ---------------------------------------------------------------------------
1736 dnl CF_LIB_SUFFIX version: 22 updated: 2013/09/07 13:54:05
1737 dnl -------------
1738 dnl Compute the library file-suffix from the given model name
1739 dnl $1 = model name
1740 dnl $2 = variable to set (the nominal library suffix)
1741 dnl $3 = dependency variable to set (actual filename)
1742 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1743 AC_DEFUN([CF_LIB_SUFFIX],
1744 [
1745         case X$1 in #(vi
1746         Xlibtool) #(vi
1747                 $2='.la'
1748                 $3=[$]$2
1749                 ;;
1750         Xdebug) #(vi
1751                 $2='_g.a'
1752                 $3=[$]$2
1753                 ;;
1754         Xprofile) #(vi
1755                 $2='_p.a'
1756                 $3=[$]$2
1757                 ;;
1758         Xshared) #(vi
1759                 case $cf_cv_system_name in
1760                 aix[[5-7]]*) #(vi
1761                         $2='.a'
1762                         $3=[$]$2
1763                         ;;
1764                 cygwin*|msys*|mingw*) #(vi
1765                         $2='.dll'
1766                         $3='.dll.a'
1767                         ;;
1768                 darwin*) #(vi
1769                         $2='.dylib'
1770                         $3=[$]$2
1771                         ;;
1772                 hpux*) #(vi
1773                         case $target in
1774                         ia64*) #(vi
1775                                 $2='.so'
1776                                 $3=[$]$2
1777                                 ;;
1778                         *) #(vi
1779                                 $2='.sl'
1780                                 $3=[$]$2
1781                                 ;;
1782                         esac
1783                         ;;
1784                 *) #(vi
1785                         $2='.so'
1786                         $3=[$]$2
1787                         ;;
1788                 esac
1789                 ;;
1790         *)
1791                 $2='.a'
1792                 $3=[$]$2
1793                 ;;
1794         esac
1795         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
1796         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
1797 ])dnl
1798 dnl ---------------------------------------------------------------------------
1799 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
1800 dnl -----------
1801 dnl Compute the string to append to -library from the given model name
1802 dnl $1 = model name
1803 dnl $2 = variable to set
1804 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1805 AC_DEFUN([CF_LIB_TYPE],
1806 [
1807         case $1 in
1808         libtool) $2=''   ;;
1809         normal)  $2=''   ;;
1810         debug)   $2='_g' ;;
1811         profile) $2='_p' ;;
1812         shared)  $2=''   ;;
1813         esac
1814         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
1815 ])dnl
1816 dnl ---------------------------------------------------------------------------
1817 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
1818 dnl ----------------
1819 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
1820 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
1821 dnl have to provide wrappers for global tables to ensure they're linked
1822 dnl properly.
1823 AC_DEFUN([CF_LINK_DATAONLY],
1824 [
1825 AC_MSG_CHECKING([if data-only library module links])
1826 AC_CACHE_VAL(cf_cv_link_dataonly,[
1827         rm -f conftest.a
1828         cat >conftest.$ac_ext <<EOF
1829 #line __oline__ "configure"
1830 int     testdata[[3]] = { 123, 456, 789 };
1831 EOF
1832         if AC_TRY_EVAL(ac_compile) ; then
1833                 mv conftest.o data.o && \
1834                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
1835         fi
1836         rm -f conftest.$ac_ext data.o
1837         cat >conftest.$ac_ext <<EOF
1838 #line __oline__ "configure"
1839 int     testfunc()
1840 {
1841 #if defined(NeXT)
1842         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
1843 #else
1844         extern int testdata[[3]];
1845         return testdata[[0]] == 123
1846            &&  testdata[[1]] == 456
1847            &&  testdata[[2]] == 789;
1848 #endif
1849 }
1850 EOF
1851         if AC_TRY_EVAL(ac_compile); then
1852                 mv conftest.o func.o && \
1853                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
1854         fi
1855         rm -f conftest.$ac_ext func.o
1856         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
1857         cf_saveLIBS="$LIBS"
1858         LIBS="conftest.a $LIBS"
1859         AC_TRY_RUN([
1860         int main()
1861         {
1862                 extern int testfunc();
1863                 ${cf_cv_main_return:-return} (!testfunc());
1864         }
1865         ],
1866         [cf_cv_link_dataonly=yes],
1867         [cf_cv_link_dataonly=no],
1868         [cf_cv_link_dataonly=unknown])
1869         LIBS="$cf_saveLIBS"
1870         ])
1871 AC_MSG_RESULT($cf_cv_link_dataonly)
1872
1873 if test "$cf_cv_link_dataonly" = no ; then
1874         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
1875         BROKEN_LINKER=1
1876 fi
1877
1878 ])dnl
1879 dnl ---------------------------------------------------------------------------
1880 dnl CF_MAKEFLAGS version: 15 updated: 2014/05/10 16:43:23
1881 dnl ------------
1882 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
1883 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
1884 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
1885 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
1886 AC_DEFUN([CF_MAKEFLAGS],
1887 [
1888 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
1889         cf_cv_makeflags=''
1890         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
1891         do
1892                 cat >cf_makeflags.tmp <<CF_EOF
1893 SHELL = /bin/sh
1894 all :
1895         @ echo '.$cf_option'
1896 CF_EOF
1897                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
1898                 case "$cf_result" in
1899                 .*k|.*kw)
1900                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
1901                         case "$cf_result" in
1902                         .*CC=*) cf_cv_makeflags=
1903                                 ;;
1904                         *)      cf_cv_makeflags=$cf_option
1905                                 ;;
1906                         esac
1907                         break
1908                         ;;
1909                 .-)     ;;
1910                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
1911                         ;;
1912                 esac
1913         done
1914         rm -f cf_makeflags.tmp
1915 ])
1916
1917 AC_SUBST(cf_cv_makeflags)
1918 ])dnl
1919 dnl ---------------------------------------------------------------------------
1920 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
1921 dnl ------------
1922 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
1923 dnl a monocase filesystem.
1924 AC_DEFUN([CF_MAKE_TAGS],[
1925 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
1926
1927 AC_CHECK_PROGS(CTAGS, exctags ctags)
1928 AC_CHECK_PROGS(ETAGS, exetags etags)
1929
1930 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
1931
1932 if test "$cf_cv_mixedcase" = yes ; then
1933         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
1934 else
1935         MAKE_UPPER_TAGS=no
1936 fi
1937
1938 if test "$MAKE_UPPER_TAGS" = yes ; then
1939         MAKE_UPPER_TAGS=
1940 else
1941         MAKE_UPPER_TAGS="#"
1942 fi
1943
1944 if test "$MAKE_LOWER_TAGS" = yes ; then
1945         MAKE_LOWER_TAGS=
1946 else
1947         MAKE_LOWER_TAGS="#"
1948 fi
1949
1950 AC_SUBST(CTAGS)
1951 AC_SUBST(ETAGS)
1952
1953 AC_SUBST(MAKE_UPPER_TAGS)
1954 AC_SUBST(MAKE_LOWER_TAGS)
1955 ])dnl
1956 dnl ---------------------------------------------------------------------------
1957 dnl CF_MIXEDCASE_FILENAMES version: 6 updated: 2013/10/08 17:47:05
1958 dnl ----------------------
1959 dnl Check if the file-system supports mixed-case filenames.  If we're able to
1960 dnl create a lowercase name and see it as uppercase, it doesn't support that.
1961 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
1962 [
1963 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
1964 if test "$cross_compiling" = yes ; then
1965         case $target_alias in #(vi
1966         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*) #(vi
1967                 cf_cv_mixedcase=no
1968                 ;;
1969         *)
1970                 cf_cv_mixedcase=yes
1971                 ;;
1972         esac
1973 else
1974         rm -f conftest CONFTEST
1975         echo test >conftest
1976         if test -f CONFTEST ; then
1977                 cf_cv_mixedcase=no
1978         else
1979                 cf_cv_mixedcase=yes
1980         fi
1981         rm -f conftest CONFTEST
1982 fi
1983 ])
1984 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
1985 ])dnl
1986 dnl ---------------------------------------------------------------------------
1987 dnl CF_MKSTEMP version: 9 updated: 2012/10/03 04:34:49
1988 dnl ----------
1989 dnl Check for a working mkstemp.  This creates two files, checks that they are
1990 dnl successfully created and distinct (AmigaOS apparently fails on the last).
1991 AC_DEFUN([CF_MKSTEMP],[
1992 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
1993 rm -rf conftest*
1994 AC_TRY_RUN([
1995 #include <sys/types.h>
1996 #include <stdlib.h>
1997 #include <stdio.h>
1998 #include <string.h>
1999 #include <sys/stat.h>
2000 int main()
2001 {
2002         char *tmpl = "conftestXXXXXX";
2003         char name[2][80];
2004         int n;
2005         int result = 0;
2006         int fd;
2007         struct stat sb;
2008
2009         umask(077);
2010         for (n = 0; n < 2; ++n) {
2011                 strcpy(name[n], tmpl);
2012                 if ((fd = mkstemp(name[n])) >= 0) {
2013                         if (!strcmp(name[n], tmpl)
2014                          || stat(name[n], &sb) != 0
2015                          || (sb.st_mode & S_IFMT) != S_IFREG
2016                          || (sb.st_mode & 077) != 0) {
2017                                 result = 1;
2018                         }
2019                         close(fd);
2020                 }
2021         }
2022         if (result == 0
2023          && !strcmp(name[0], name[1]))
2024                 result = 1;
2025         ${cf_cv_main_return:-return}(result);
2026 }
2027 ],[cf_cv_func_mkstemp=yes
2028 ],[cf_cv_func_mkstemp=no
2029 ],[cf_cv_func_mkstemp=maybe])
2030 ])
2031 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
2032         AC_CHECK_FUNC(mkstemp)
2033 fi
2034 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
2035         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
2036 fi
2037 ])dnl
2038 dnl ---------------------------------------------------------------------------
2039 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2040 dnl ----------
2041 dnl Write a debug message to config.log, along with the line number in the
2042 dnl configure script.
2043 AC_DEFUN([CF_MSG_LOG],[
2044 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2045 ])dnl
2046 dnl ---------------------------------------------------------------------------
2047 dnl CF_NCURSES_ADDON version: 4 updated: 2011/03/27 17:10:13
2048 dnl ----------------
2049 dnl Configure an ncurses add-on, built outside the ncurses tree.
2050 AC_DEFUN([CF_NCURSES_ADDON],[
2051
2052 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
2053
2054 AC_MSG_CHECKING(if you want wide-character code)
2055 AC_ARG_ENABLE(widec,
2056         [  --enable-widec          compile with wide-char/UTF-8 code],
2057         [with_widec=$enableval],
2058         [with_widec=no])
2059 AC_MSG_RESULT($with_widec)
2060 if test "$with_widec" = yes ; then
2061         CF_UTF8_LIB 
2062         CF_NCURSES_CONFIG(ncursesw)
2063 else
2064         CF_NCURSES_CONFIG(ncurses)
2065 fi
2066
2067 if test "$NCURSES_CONFIG" != none ; then
2068
2069 cf_version=`$NCURSES_CONFIG --version`
2070
2071 NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2072 NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2073 NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2074
2075 # ABI version is not available from headers
2076 cf_cv_abi_version=`$NCURSES_CONFIG --abi-version`
2077
2078 else
2079
2080 for cf_name in MAJOR MINOR PATCH
2081 do
2082 cat >conftest.$ac_ext <<CF_EOF
2083 #include <${cf_cv_ncurses_header:-curses.h}>
2084 AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
2085 CF_EOF
2086         cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
2087         AC_TRY_EVAL(cf_try)
2088         if test -f conftest.out ; then
2089                 cf_result=`cat conftest.out | sed -e "s/^.*AUTOCONF_$cf_name[[  ]][[    ]]*//"`
2090                 eval NCURSES_$cf_name=\"$cf_result\"
2091                 # cat conftest.$ac_ext
2092                 # cat conftest.out
2093         fi
2094 done
2095
2096 cf_cv_abi_version=${NCURSES_MAJOR}
2097
2098 fi
2099
2100 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
2101
2102 dnl Show the computed version, for logging
2103 cf_cv_timestamp=`date`
2104
2105 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
2106
2107 dnl We need these values in the generated headers
2108 AC_SUBST(NCURSES_MAJOR)
2109 AC_SUBST(NCURSES_MINOR)
2110 AC_SUBST(NCURSES_PATCH)
2111
2112 dnl We need these values in the generated makefiles
2113 AC_SUBST(cf_cv_rel_version)
2114 AC_SUBST(cf_cv_abi_version)
2115
2116 dnl FIXME - not needed for Ada95
2117 AC_SUBST(cf_cv_builtin_bool)
2118 AC_SUBST(cf_cv_header_stdbool_h)
2119 AC_SUBST(cf_cv_type_of_bool)dnl
2120
2121 ])
2122 dnl ---------------------------------------------------------------------------
2123 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2124 dnl -------------------
2125 dnl Check if we can compile with ncurses' header file
2126 dnl $1 is the cache variable to set
2127 dnl $2 is the header-file to include
2128 dnl $3 is the root name (ncurses or ncursesw)
2129 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2130         AC_TRY_COMPILE([
2131 ]ifelse($3,ncursesw,[
2132 #define _XOPEN_SOURCE_EXTENDED
2133 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2134 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2135 ])[
2136 #include <$2>],[
2137 #ifdef NCURSES_VERSION
2138 ]ifelse($3,ncursesw,[
2139 #ifndef WACS_BSSB
2140         make an error
2141 #endif
2142 ])[
2143 printf("%s\n", NCURSES_VERSION);
2144 #else
2145 #ifdef __NCURSES_H
2146 printf("old\n");
2147 #else
2148         make an error
2149 #endif
2150 #endif
2151         ]
2152         ,[$1=$2]
2153         ,[$1=no])
2154 ])dnl
2155 dnl ---------------------------------------------------------------------------
2156 dnl CF_NCURSES_CONFIG version: 10 updated: 2012/10/06 08:57:51
2157 dnl -----------------
2158 dnl Tie together the configure-script macros for ncurses.
2159 dnl Prefer the "-config" script from ncurses 6.x, to simplify analysis.
2160 dnl Allow that to be overridden using the $NCURSES_CONFIG environment variable.
2161 dnl
2162 dnl $1 is the root library name (default: "ncurses")
2163 AC_DEFUN([CF_NCURSES_CONFIG],
2164 [
2165 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2166
2167 echo "Looking for ${cf_ncuconfig_root}-config"
2168
2169 CF_ACVERSION_CHECK(2.52,
2170         [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2171         [AC_PATH_PROGS(NCURSES_CONFIG, ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2172
2173 if test "$NCURSES_CONFIG" != none ; then
2174
2175 CPPFLAGS="$CPPFLAGS `$NCURSES_CONFIG --cflags`"
2176 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2177
2178 # even with config script, some packages use no-override for curses.h
2179 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2180
2181 dnl like CF_NCURSES_CPPFLAGS
2182 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2183
2184 dnl like CF_NCURSES_LIBS
2185 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2186 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2187
2188 dnl like CF_NCURSES_VERSION
2189 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2190
2191 else
2192
2193 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2194 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2195
2196 fi
2197 ])dnl
2198 dnl ---------------------------------------------------------------------------
2199 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
2200 dnl -------------------
2201 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2202 dnl the CPPFLAGS variable so we can include its header.
2203 dnl
2204 dnl The header files may be installed as either curses.h, or ncurses.h (would
2205 dnl be obsolete, except that some packagers prefer this name to distinguish it
2206 dnl from a "native" curses implementation).  If not installed for overwrite,
2207 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2208 dnl /usr/include/ncurses), but someone may have installed overwriting the
2209 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2210 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2211 dnl the header.
2212 dnl
2213 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2214 dnl is already in the include-path, don't even bother with this, since we cannot
2215 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2216 dnl
2217 dnl The optional parameter gives the root name of the library, in case it is
2218 dnl not installed as the default curses library.  That is how the
2219 dnl wide-character version of ncurses is installed.
2220 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2221 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2222
2223 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2224 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2225
2226 test -n "$cf_cv_curses_dir" && \
2227 test "$cf_cv_curses_dir" != "no" && { \
2228   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2229 }
2230
2231 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2232         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2233         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2234         for cf_header in $cf_header_list
2235         do
2236                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2237                 test "$cf_cv_ncurses_h" != no && break
2238         done
2239 ])
2240
2241 CF_NCURSES_HEADER
2242 CF_TERM_HEADER
2243
2244 # some applications need this, but should check for NCURSES_VERSION
2245 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2246
2247 CF_NCURSES_VERSION
2248 ])dnl
2249 dnl ---------------------------------------------------------------------------
2250 dnl CF_NCURSES_HEADER version: 3 updated: 2012/10/06 08:57:51
2251 dnl -----------------
2252 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2253 dnl variations of ncurses' installs.
2254 dnl
2255 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2256 AC_DEFUN([CF_NCURSES_HEADER],[
2257
2258 if test "$cf_cv_ncurses_h" != no ; then
2259         cf_cv_ncurses_header=$cf_cv_ncurses_h
2260 else
2261
2262 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2263         test -n "$verbose" && echo
2264         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2265         test -n "$verbose" && echo search path $cf_search
2266         cf_save2_CPPFLAGS="$CPPFLAGS"
2267         for cf_incdir in $cf_search
2268         do
2269                 CF_ADD_INCDIR($cf_incdir)
2270                 for cf_header in \
2271                         ncurses.h \
2272                         curses.h
2273                 do
2274                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2275                         if test "$cf_cv_ncurses_h2" != no ; then
2276                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2277                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2278                                 break
2279                         fi
2280                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2281                 done
2282                 CPPFLAGS="$cf_save2_CPPFLAGS"
2283                 test "$cf_cv_ncurses_h2" != no && break
2284         done
2285         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2286         ])
2287
2288         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2289         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2290         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2291                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2292         fi
2293         CF_ADD_INCDIR($cf_1st_incdir)
2294
2295 fi
2296
2297 # Set definitions to allow ifdef'ing for ncurses.h
2298
2299 case $cf_cv_ncurses_header in # (vi
2300 *ncurses.h)
2301         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2302         ;;
2303 esac
2304
2305 case $cf_cv_ncurses_header in # (vi
2306 ncurses/curses.h|ncurses/ncurses.h)
2307         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2308         ;;
2309 ncursesw/curses.h|ncursesw/ncurses.h)
2310         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2311         ;;
2312 esac
2313
2314 ])dnl
2315 dnl ---------------------------------------------------------------------------
2316 dnl CF_NCURSES_LIBS version: 16 updated: 2010/11/20 17:02:38
2317 dnl ---------------
2318 dnl Look for the ncurses library.  This is a little complicated on Linux,
2319 dnl because it may be linked with the gpm (general purpose mouse) library.
2320 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2321 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2322 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2323 dnl and the linker will record a dependency.
2324 dnl
2325 dnl The optional parameter gives the root name of the library, in case it is
2326 dnl not installed as the default curses library.  That is how the
2327 dnl wide-character version of ncurses is installed.
2328 AC_DEFUN([CF_NCURSES_LIBS],
2329 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2330
2331 cf_nculib_root=ifelse($1,,ncurses,$1)
2332         # This works, except for the special case where we find gpm, but
2333         # ncurses is in a nonstandard location via $LIBS, and we really want
2334         # to link gpm.
2335 cf_ncurses_LIBS=""
2336 cf_ncurses_SAVE="$LIBS"
2337 AC_CHECK_LIB(gpm,Gpm_Open,
2338         [AC_CHECK_LIB(gpm,initscr,
2339                 [LIBS="$cf_ncurses_SAVE"],
2340                 [cf_ncurses_LIBS="-lgpm"])])
2341
2342 case $host_os in #(vi
2343 freebsd*)
2344         # This is only necessary if you are linking against an obsolete
2345         # version of ncurses (but it should do no harm, since it's static).
2346         if test "$cf_nculib_root" = ncurses ; then
2347                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2348         fi
2349         ;;
2350 esac
2351
2352 CF_ADD_LIBS($cf_ncurses_LIBS)
2353
2354 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2355 then
2356         CF_ADD_LIBS(-l$cf_nculib_root)
2357 else
2358         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2359                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2360                 [initscr()],
2361                 initscr)
2362 fi
2363
2364 if test -n "$cf_ncurses_LIBS" ; then
2365         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2366         cf_ncurses_SAVE="$LIBS"
2367         for p in $cf_ncurses_LIBS ; do
2368                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2369                 if test "$q" != "$LIBS" ; then
2370                         LIBS="$q"
2371                 fi
2372         done
2373         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2374                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2375                 [AC_MSG_RESULT(yes)],
2376                 [AC_MSG_RESULT(no)
2377                  LIBS="$cf_ncurses_SAVE"])
2378 fi
2379
2380 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2381 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2382 ])dnl
2383 dnl ---------------------------------------------------------------------------
2384 dnl CF_NCURSES_VERSION version: 14 updated: 2012/10/06 08:57:51
2385 dnl ------------------
2386 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2387 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2388 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2389 AC_DEFUN([CF_NCURSES_VERSION],
2390 [
2391 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2392 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2393         cf_cv_ncurses_version=no
2394         cf_tempfile=out$$
2395         rm -f $cf_tempfile
2396         AC_TRY_RUN([
2397 #include <${cf_cv_ncurses_header:-curses.h}>
2398 #include <stdio.h>
2399 int main()
2400 {
2401         FILE *fp = fopen("$cf_tempfile", "w");
2402 #ifdef NCURSES_VERSION
2403 # ifdef NCURSES_VERSION_PATCH
2404         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2405 # else
2406         fprintf(fp, "%s\n", NCURSES_VERSION);
2407 # endif
2408 #else
2409 # ifdef __NCURSES_H
2410         fprintf(fp, "old\n");
2411 # else
2412         make an error
2413 # endif
2414 #endif
2415         ${cf_cv_main_return:-return}(0);
2416 }],[
2417         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2418
2419         # This will not work if the preprocessor splits the line after the
2420         # Autoconf token.  The 'unproto' program does that.
2421         cat > conftest.$ac_ext <<EOF
2422 #include <${cf_cv_ncurses_header:-curses.h}>
2423 #undef Autoconf
2424 #ifdef NCURSES_VERSION
2425 Autoconf NCURSES_VERSION
2426 #else
2427 #ifdef __NCURSES_H
2428 Autoconf "old"
2429 #endif
2430 ;
2431 #endif
2432 EOF
2433         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2434         AC_TRY_EVAL(cf_try)
2435         if test -f conftest.out ; then
2436                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2437                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2438                 rm -f conftest.out
2439         fi
2440 ])
2441         rm -f $cf_tempfile
2442 ])
2443 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2444 ])dnl
2445 dnl ---------------------------------------------------------------------------
2446 dnl CF_OBJ_SUBDIR version: 6 updated: 2013/09/07 14:06:10
2447 dnl -------------
2448 dnl Compute the object-directory name from the given model name
2449 AC_DEFUN([CF_OBJ_SUBDIR],
2450 [
2451         case $1 in
2452         libtool) $2='obj_lo'  ;;
2453         normal)  $2='objects' ;;
2454         debug)   $2='obj_g' ;;
2455         profile) $2='obj_p' ;;
2456         shared)
2457                 case $cf_cv_system_name in #(vi
2458                 cygwin|msys) #(vi
2459                         $2='objects' ;;
2460                 *)
2461                         $2='obj_s' ;;
2462                 esac
2463         esac
2464 ])dnl
2465 dnl ---------------------------------------------------------------------------
2466 dnl CF_PATHSEP version: 6 updated: 2012/09/29 18:38:12
2467 dnl ----------
2468 dnl Provide a value for the $PATH and similar separator (or amend the value
2469 dnl as provided in autoconf 2.5x).
2470 AC_DEFUN([CF_PATHSEP],
2471 [
2472         AC_MSG_CHECKING(for PATH separator)
2473         case $cf_cv_system_name in
2474         os2*)   PATH_SEPARATOR=';'  ;;
2475         *)      ${PATH_SEPARATOR:=':'}  ;;
2476         esac
2477 ifelse([$1],,,[$1=$PATH_SEPARATOR])
2478         AC_SUBST(PATH_SEPARATOR)
2479         AC_MSG_RESULT($PATH_SEPARATOR)
2480 ])dnl
2481 dnl ---------------------------------------------------------------------------
2482 dnl CF_PATH_SYNTAX version: 14 updated: 2012/06/19 20:58:54
2483 dnl --------------
2484 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2485 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2486 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2487 dnl delayed evaluation of those symbols.
2488 AC_DEFUN([CF_PATH_SYNTAX],[
2489 if test "x$prefix" != xNONE; then
2490   cf_path_syntax="$prefix"
2491 else
2492   cf_path_syntax="$ac_default_prefix"
2493 fi
2494
2495 case ".[$]$1" in #(vi
2496 .\[$]\(*\)*|.\'*\'*) #(vi
2497   ;;
2498 ..|./*|.\\*) #(vi
2499   ;;
2500 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
2501   ;;
2502 .\[$]{*prefix}*|.\[$]{*dir}*) #(vi
2503   eval $1="[$]$1"
2504   case ".[$]$1" in #(vi
2505   .NONE/*)
2506     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2507     ;;
2508   esac
2509   ;; #(vi
2510 .no|.NONE/*)
2511   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2512   ;;
2513 *)
2514   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2515   ;;
2516 esac
2517 ])dnl
2518 dnl ---------------------------------------------------------------------------
2519 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
2520 dnl -------------
2521 dnl Check for the package-config program, unless disabled by command-line.
2522 AC_DEFUN([CF_PKG_CONFIG],
2523 [
2524 AC_MSG_CHECKING(if you want to use pkg-config)
2525 AC_ARG_WITH(pkg-config,
2526         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2527         [cf_pkg_config=$withval],
2528         [cf_pkg_config=yes])
2529 AC_MSG_RESULT($cf_pkg_config)
2530
2531 case $cf_pkg_config in #(vi
2532 no) #(vi
2533         PKG_CONFIG=none
2534         ;;
2535 yes) #(vi
2536         CF_ACVERSION_CHECK(2.52,
2537                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2538                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2539         ;;
2540 *)
2541         PKG_CONFIG=$withval
2542         ;;
2543 esac
2544
2545 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2546 if test "$PKG_CONFIG" != none ; then
2547         CF_PATH_SYNTAX(PKG_CONFIG)
2548 fi
2549
2550 AC_SUBST(PKG_CONFIG)
2551 ])dnl
2552 dnl ---------------------------------------------------------------------------
2553 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
2554 dnl -----------------
2555 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2556 dnl
2557 dnl     POSIX.1-1990                            _POSIX_SOURCE
2558 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2559 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2560 dnl             Bindings Option
2561 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2562 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2563 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2564 dnl
2565 dnl Parameters:
2566 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2567 AC_DEFUN([CF_POSIX_C_SOURCE],
2568 [
2569 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2570
2571 cf_save_CFLAGS="$CFLAGS"
2572 cf_save_CPPFLAGS="$CPPFLAGS"
2573
2574 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2575 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2576
2577 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2578         CF_MSG_LOG(if the symbol is already defined go no further)
2579         AC_TRY_COMPILE([#include <sys/types.h>],[
2580 #ifndef _POSIX_C_SOURCE
2581 make an error
2582 #endif],
2583         [cf_cv_posix_c_source=no],
2584         [cf_want_posix_source=no
2585          case .$cf_POSIX_C_SOURCE in #(vi
2586          .[[12]]??*) #(vi
2587                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2588                 ;;
2589          .2) #(vi
2590                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2591                 cf_want_posix_source=yes
2592                 ;;
2593          .*)
2594                 cf_want_posix_source=yes
2595                 ;;
2596          esac
2597          if test "$cf_want_posix_source" = yes ; then
2598                 AC_TRY_COMPILE([#include <sys/types.h>],[
2599 #ifdef _POSIX_SOURCE
2600 make an error
2601 #endif],[],
2602                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2603          fi
2604          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2605          CFLAGS="$cf_trim_CFLAGS"
2606          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
2607          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2608          AC_TRY_COMPILE([#include <sys/types.h>],[
2609 #ifndef _POSIX_C_SOURCE
2610 make an error
2611 #endif],,
2612          [cf_cv_posix_c_source=no])
2613          CFLAGS="$cf_save_CFLAGS"
2614          CPPFLAGS="$cf_save_CPPFLAGS"
2615         ])
2616 ])
2617
2618 if test "$cf_cv_posix_c_source" != no ; then
2619         CFLAGS="$cf_trim_CFLAGS"
2620         CPPFLAGS="$cf_trim_CPPFLAGS"
2621         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2622 fi
2623
2624 ])dnl
2625 dnl ---------------------------------------------------------------------------
2626 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
2627 dnl ----------
2628 dnl Check for archiver "ar".
2629 AC_DEFUN([CF_PROG_AR],[
2630 AC_CHECK_TOOL(AR, ar, ar)
2631 ])
2632 dnl ---------------------------------------------------------------------------
2633 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
2634 dnl -----------
2635 dnl Check for awk, ensure that the check found something.
2636 AC_DEFUN([CF_PROG_AWK],
2637 [
2638 AC_PROG_AWK
2639 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
2640 ])dnl
2641 dnl ---------------------------------------------------------------------------
2642 dnl CF_PROG_CC version: 3 updated: 2012/10/06 15:31:55
2643 dnl ----------
2644 dnl standard check for CC, plus followup sanity checks
2645 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
2646 AC_DEFUN([CF_PROG_CC],[
2647 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
2648 CF_GCC_VERSION
2649 CF_ACVERSION_CHECK(2.52,
2650         [AC_PROG_CC_STDC],
2651         [CF_ANSI_CC_REQD])
2652 CF_CC_ENV_FLAGS 
2653 ])dnl
2654 dnl ---------------------------------------------------------------------------
2655 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
2656 dnl --------------
2657 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
2658 dnl the output file can be renamed, and allows for a shell variable that can
2659 dnl be used later.  The parameter is either CC or CXX.  The result is the
2660 dnl cache variable:
2661 dnl     $cf_cv_prog_CC_c_o
2662 dnl     $cf_cv_prog_CXX_c_o
2663 AC_DEFUN([CF_PROG_CC_C_O],
2664 [AC_REQUIRE([AC_PROG_CC])dnl
2665 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
2666 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
2667 [
2668 cat > conftest.$ac_ext <<CF_EOF
2669 #include <stdio.h>
2670 int main()
2671 {
2672         ${cf_cv_main_return:-return}(0);
2673 }
2674 CF_EOF
2675 # We do the test twice because some compilers refuse to overwrite an
2676 # existing .o file with -o, though they will create one.
2677 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
2678 if AC_TRY_EVAL(ac_try) &&
2679   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
2680 then
2681   eval cf_cv_prog_$1_c_o=yes
2682 else
2683   eval cf_cv_prog_$1_c_o=no
2684 fi
2685 rm -rf conftest*
2686 ])dnl
2687 if test $cf_cv_prog_$1_c_o = yes; then
2688   AC_MSG_RESULT([yes])
2689 else
2690   AC_MSG_RESULT([no])
2691 fi
2692 ])dnl
2693 dnl ---------------------------------------------------------------------------
2694 dnl CF_PROG_EGREP version: 1 updated: 2006/09/16 11:40:59
2695 dnl -------------
2696 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
2697 dnl This macro adds a check to ensure the script found something.
2698 AC_DEFUN([CF_PROG_EGREP],
2699 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
2700    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
2701     then ac_cv_prog_egrep='grep -E'
2702     else ac_cv_prog_egrep='egrep'
2703     fi])
2704  EGREP=$ac_cv_prog_egrep
2705  AC_SUBST([EGREP])
2706 test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
2707 ])dnl
2708 dnl ---------------------------------------------------------------------------
2709 dnl CF_PROG_EXT version: 11 updated: 2012/10/06 08:57:51
2710 dnl -----------
2711 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
2712 AC_DEFUN([CF_PROG_EXT],
2713 [
2714 AC_REQUIRE([CF_CHECK_CACHE])
2715 case $cf_cv_system_name in
2716 os2*)
2717     CFLAGS="$CFLAGS -Zmt"
2718     CPPFLAGS="$CPPFLAGS -D__ST_MT_ERRNO__"
2719     CXXFLAGS="$CXXFLAGS -Zmt"
2720     # autoconf's macro sets -Zexe and suffix both, which conflict:w
2721     LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
2722     ac_cv_exeext=.exe
2723     ;;
2724 esac
2725
2726 AC_EXEEXT
2727 AC_OBJEXT
2728
2729 PROG_EXT="$EXEEXT"
2730 AC_SUBST(PROG_EXT)
2731 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT",[Define to the program extension (normally blank)])
2732 ])dnl
2733 dnl ---------------------------------------------------------------------------
2734 dnl CF_PROG_GNAT version: 2 updated: 2011/10/22 14:01:47
2735 dnl ------------
2736 dnl Check for gnatmake, ensure that it is complete.
2737 AC_DEFUN([CF_PROG_GNAT],[
2738 cf_ada_make=gnatmake
2739 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
2740 if test "$ac_cv_prog_gnat_exists" = no; then
2741    cf_ada_make=
2742    cf_cv_prog_gnat_correct=no
2743 else
2744    CF_GNAT_VERSION
2745    AC_CHECK_PROG(M4_exists, m4, yes, no)
2746    if test "$ac_cv_prog_M4_exists" = no; then
2747       cf_cv_prog_gnat_correct=no
2748       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
2749    fi
2750    if test "$cf_cv_prog_gnat_correct" = yes; then
2751       AC_MSG_CHECKING(if GNAT works)
2752       CF_GNAT_TRY_RUN([procedure conftest;],
2753 [with Text_IO;
2754 with GNAT.OS_Lib;
2755 procedure conftest is
2756 begin
2757    Text_IO.Put ("Hello World");
2758    Text_IO.New_Line;
2759    GNAT.OS_Lib.OS_Exit (0);
2760 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
2761       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
2762    fi
2763 fi
2764
2765 AC_SUBST(cf_ada_make)
2766 ])dnl
2767 dnl ---------------------------------------------------------------------------
2768 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
2769 dnl ------------
2770 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
2771 dnl option if it is supported.
2772 AC_DEFUN([CF_PROG_LN_S],[
2773 AC_PROG_LN_S
2774 AC_MSG_CHECKING(if $LN_S -f options work)
2775
2776 rm -f conf$$.src conf$$dst
2777 echo >conf$$.dst
2778 echo first >conf$$.src
2779 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
2780         cf_prog_ln_sf=yes
2781 else
2782         cf_prog_ln_sf=no
2783 fi
2784 rm -f conf$$.dst conf$$src
2785 AC_MSG_RESULT($cf_prog_ln_sf)
2786
2787 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
2788 ])dnl
2789 dnl ---------------------------------------------------------------------------
2790 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
2791 dnl ----------------
2792 dnl Remove all -U and -D options that refer to the given symbol from a list
2793 dnl of C compiler options.  This works around the problem that not all
2794 dnl compilers process -U and -D options from left-to-right, so a -U option
2795 dnl cannot be used to cancel the effect of a preceding -D option.
2796 dnl
2797 dnl $1 = target (which could be the same as the source variable)
2798 dnl $2 = source (including '$')
2799 dnl $3 = symbol to remove
2800 define([CF_REMOVE_DEFINE],
2801 [
2802 $1=`echo "$2" | \
2803         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
2804                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
2805 ])dnl
2806 dnl ---------------------------------------------------------------------------
2807 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
2808 dnl -------------
2809 dnl Remove the given library from the symbol
2810 dnl
2811 dnl $1 = target (which could be the same as the source variable)
2812 dnl $2 = source (including '$')
2813 dnl $3 = library to remove
2814 define([CF_REMOVE_LIB],
2815 [
2816 # remove $3 library from $2
2817 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
2818 ])dnl
2819 dnl ---------------------------------------------------------------------------
2820 dnl CF_SHARED_OPTS version: 84 updated: 2013/11/03 06:26:10
2821 dnl --------------
2822 dnl --------------
2823 dnl Attempt to determine the appropriate CC/LD options for creating a shared
2824 dnl library.
2825 dnl
2826 dnl Notes:
2827 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
2828 dnl the build-tree, i.e., by making use of the libraries that are compiled in
2829 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
2830 dnl shared library since that can lead to unexpected results at runtime.
2831 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
2832 dnl libraries are compiled in ../../lib
2833 dnl
2834 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
2835 dnl to install symbolic links to the rel/abi versions of shared libraries.
2836 dnl
2837 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
2838 dnl version when making symbolic links.
2839 dnl
2840 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
2841 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
2842 dnl (ex: libncurses.so.<ver>).
2843 dnl
2844 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
2845 AC_DEFUN([CF_SHARED_OPTS],
2846 [
2847         AC_REQUIRE([CF_LD_RPATH_OPT])
2848         RM_SHARED_OPTS=
2849         LOCAL_LDFLAGS=
2850         LOCAL_LDFLAGS2=
2851         LD_SHARED_OPTS=
2852         INSTALL_LIB="-m 644"
2853         : ${rel_builddir:=.}
2854
2855         shlibdir=$libdir
2856         AC_SUBST(shlibdir)
2857
2858         MAKE_DLLS="#"
2859         AC_SUBST(MAKE_DLLS)
2860
2861         cf_cv_do_symlinks=no
2862         cf_ld_rpath_opt=
2863         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
2864
2865         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
2866         AC_ARG_WITH(shlib-version,
2867         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
2868         [test -z "$withval" && withval=auto
2869         case $withval in #(vi
2870         yes) #(vi
2871                 cf_cv_shlib_version=auto
2872                 ;;
2873         rel|abi|auto|no) #(vi
2874                 cf_cv_shlib_version=$withval
2875                 ;;
2876         *)
2877                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
2878                 ;;
2879         esac
2880         ],[cf_cv_shlib_version=auto])
2881         AC_MSG_RESULT($cf_cv_shlib_version)
2882
2883         cf_cv_rm_so_locs=no
2884         cf_try_cflags=
2885
2886         # Some less-capable ports of gcc support only -fpic
2887         CC_SHARED_OPTS=
2888         if test "$GCC" = yes
2889         then
2890                 AC_MSG_CHECKING(which $CC option to use)
2891                 cf_save_CFLAGS="$CFLAGS"
2892                 for CC_SHARED_OPTS in -fPIC -fpic ''
2893                 do
2894                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
2895                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
2896                 done
2897                 AC_MSG_RESULT($CC_SHARED_OPTS)
2898                 CFLAGS="$cf_save_CFLAGS"
2899         fi
2900
2901         cf_cv_shlib_version_infix=no
2902
2903         case $cf_cv_system_name in #(vi
2904         aix4.[3-9]*|aix[[5-7]]*) #(vi
2905                 if test "$GCC" = yes; then
2906                         CC_SHARED_OPTS=
2907                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
2908                 else
2909                         # CC_SHARED_OPTS='-qpic=large -G'
2910                         # perhaps "-bM:SRE -bnoentry -bexpall"
2911                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
2912                 fi
2913                 ;;
2914         beos*) #(vi
2915                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
2916                 ;;
2917         cygwin*) #(vi
2918                 CC_SHARED_OPTS=
2919                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
2920                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
2921                 cf_cv_shlib_version=cygdll
2922                 cf_cv_shlib_version_infix=cygdll
2923                 shlibdir=$bindir
2924                 MAKE_DLLS=
2925                 cat >mk_shared_lib.sh <<-CF_EOF
2926                 #!/bin/sh
2927                 SHARED_LIB=\[$]1
2928                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
2929                 shift
2930                 cat <<-EOF
2931                 Linking shared library
2932                 ** SHARED_LIB \[$]SHARED_LIB
2933                 ** IMPORT_LIB \[$]IMPORT_LIB
2934 EOF
2935                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
2936 CF_EOF
2937                 chmod +x mk_shared_lib.sh
2938                 ;;
2939         msys*) #(vi
2940                 CC_SHARED_OPTS=
2941                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
2942                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
2943                 cf_cv_shlib_version=msysdll
2944                 cf_cv_shlib_version_infix=msysdll
2945                 shlibdir=$bindir
2946                 MAKE_DLLS=
2947                 cat >mk_shared_lib.sh <<-CF_EOF
2948                 #!/bin/sh
2949                 SHARED_LIB=\[$]1
2950                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
2951                 shift
2952                 cat <<-EOF
2953                 Linking shared library
2954                 ** SHARED_LIB \[$]SHARED_LIB
2955                 ** IMPORT_LIB \[$]IMPORT_LIB
2956 EOF
2957                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
2958 CF_EOF
2959                 chmod +x mk_shared_lib.sh
2960                 ;;
2961         darwin*) #(vi
2962                 cf_try_cflags="no-cpp-precomp"
2963                 CC_SHARED_OPTS="-dynamic"
2964                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
2965                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
2966                 cf_cv_shlib_version_infix=yes
2967                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
2968                         cf_save_LDFLAGS=$LDFLAGS
2969                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
2970                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
2971                                 LDFLAGS=$cf_save_LDFLAGS])
2972                 if test $cf_cv_ldflags_search_paths_first = yes; then
2973                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
2974                 fi
2975                 ;;
2976         hpux[[7-8]]*) #(vi
2977                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list 
2978                 if test "$GCC" != yes; then
2979                         CC_SHARED_OPTS='+Z'
2980                 fi
2981                 MK_SHARED_LIB='${LD} -b -o $[@]'
2982                 INSTALL_LIB="-m 555"
2983                 ;;
2984         hpux*) #(vi
2985                 # (tested with gcc 2.7.2 -- I don't have c89)
2986                 if test "$GCC" = yes; then
2987                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
2988                 else
2989                         CC_SHARED_OPTS='+Z'
2990                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
2991                 fi
2992                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
2993                 # HP-UX shared libraries must be executable, and should be
2994                 # readonly to exploit a quirk in the memory manager.
2995                 INSTALL_LIB="-m 555"
2996                 ;;
2997         interix*)
2998                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
2999                 if test "$cf_cv_shlib_version" = rel; then
3000                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
3001                 else
3002                         cf_shared_soname='`basename $@`'
3003                 fi
3004                 CC_SHARED_OPTS=
3005                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
3006                 ;;
3007         irix*) #(vi
3008                 if test "$cf_cv_enable_rpath" = yes ; then
3009                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3010                 fi
3011                 # tested with IRIX 5.2 and 'cc'.
3012                 if test "$GCC" != yes; then
3013                         CC_SHARED_OPTS='-KPIC'
3014                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
3015                 else
3016                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
3017                 fi
3018                 cf_cv_rm_so_locs=yes
3019                 ;;
3020         linux*|gnu*|k*bsd*-gnu) #(vi
3021                 if test "$DFT_LWR_MODEL" = "shared" ; then
3022                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3023                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3024                 fi
3025                 if test "$cf_cv_enable_rpath" = yes ; then
3026                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3027                 fi
3028                 CF_SHARED_SONAME
3029                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3030                 ;;
3031         mingw*) #(vi
3032                 cf_cv_shlib_version=mingw
3033                 cf_cv_shlib_version_infix=mingw
3034                 shlibdir=$bindir
3035                 MAKE_DLLS=
3036                 if test "$DFT_LWR_MODEL" = "shared" ; then
3037                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
3038                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3039                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
3040                 fi
3041                 CC_SHARED_OPTS=
3042                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3043                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3044                 cat >mk_shared_lib.sh <<-CF_EOF
3045                 #!/bin/sh
3046                 SHARED_LIB=\[$]1
3047                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3048                 shift
3049                 cat <<-EOF
3050                 Linking shared library
3051                 ** SHARED_LIB \[$]SHARED_LIB
3052                 ** IMPORT_LIB \[$]IMPORT_LIB
3053 EOF
3054                 exec \[$]* -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3055 CF_EOF
3056                 chmod +x mk_shared_lib.sh
3057                 ;;
3058         openbsd[[2-9]].*|mirbsd*) #(vi
3059                 if test "$DFT_LWR_MODEL" = "shared" ; then
3060                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3061                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3062                 fi
3063                 if test "$cf_cv_enable_rpath" = yes ; then
3064                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3065                 fi
3066                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3067                 CF_SHARED_SONAME
3068                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3069                 ;;
3070         nto-qnx*|openbsd*|freebsd[[12]].*) #(vi
3071                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3072                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
3073                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3074                 ;;
3075         dragonfly*|freebsd*) #(vi
3076                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3077                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3078                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3079                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
3080                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3081                 fi
3082                 CF_SHARED_SONAME
3083                 MK_SHARED_LIB='${LD} -shared -Bshareable -soname=`basename $[@]` -o $[@]'
3084                 ;;
3085         netbsd*) #(vi
3086                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3087                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3088                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3089                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3090                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3091                         if test "$cf_cv_shlib_version" = auto; then
3092                         if test -f /usr/libexec/ld.elf_so; then
3093                                 cf_cv_shlib_version=abi
3094                         else
3095                                 cf_cv_shlib_version=rel
3096                         fi
3097                         fi
3098                         CF_SHARED_SONAME
3099                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
3100                 else
3101                         MK_SHARED_LIB='${CC} -Wl,-shared -Wl,-Bshareable -o $[@]'
3102                 fi
3103                 ;;
3104         osf*|mls+*) #(vi
3105                 # tested with OSF/1 V3.2 and 'cc'
3106                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
3107                 # link with shared libs).
3108                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
3109                 case $host_os in #(vi
3110                 osf4*)
3111                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
3112                         ;;
3113                 esac
3114                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
3115                 if test "$DFT_LWR_MODEL" = "shared" ; then
3116                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3117                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3118                 fi
3119                 cf_cv_rm_so_locs=yes
3120                 ;;
3121         sco3.2v5*)  # (also uw2* and UW7: hops 13-Apr-98
3122                 # tested with osr5.0.5
3123                 if test "$GCC" != yes; then
3124                         CC_SHARED_OPTS='-belf -KPIC'
3125                 fi
3126                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
3127                 if test "$cf_cv_enable_rpath" = yes ; then
3128                         # only way is to set LD_RUN_PATH but no switch for it
3129                         RUN_PATH=$libdir
3130                 fi
3131                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3132                 LINK_PROGS='LD_RUN_PATH=${libdir}'
3133                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
3134                 ;;
3135         sunos4*) #(vi
3136                 # tested with SunOS 4.1.1 and gcc 2.7.0
3137                 if test "$GCC" != yes; then
3138                         CC_SHARED_OPTS='-KPIC'
3139                 fi
3140                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
3141                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3142                 ;;
3143         solaris2*) #(vi
3144                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
3145                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
3146                 if test "$DFT_LWR_MODEL" = "shared" ; then
3147                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
3148                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3149                 fi
3150                 if test "$cf_cv_enable_rpath" = yes ; then
3151                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
3152                 fi
3153                 CF_SHARED_SONAME
3154                 if test "$GCC" != yes; then
3155                         cf_save_CFLAGS="$CFLAGS"
3156                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
3157                         do
3158                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
3159                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
3160                         done
3161                         CFLAGS="$cf_save_CFLAGS"
3162                         CC_SHARED_OPTS=$cf_shared_opts
3163                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3164                 else
3165                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3166                 fi
3167                 ;;
3168         sysv5uw7*|unix_sv*) #(vi
3169                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
3170                 if test "$GCC" != yes; then
3171                         CC_SHARED_OPTS='-KPIC'
3172                 fi
3173                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
3174                 ;;
3175         *)
3176                 CC_SHARED_OPTS='unknown'
3177                 MK_SHARED_LIB='echo unknown'
3178                 ;;
3179         esac
3180
3181         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
3182         case "$cf_cv_shlib_version" in #(vi
3183         rel|abi)
3184                 case "$MK_SHARED_LIB" in #(vi
3185                 *'-o $[@]') #(vi
3186                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
3187                         ;;
3188                 *)
3189                         AC_MSG_WARN(ignored --with-shlib-version)
3190                         ;;
3191                 esac
3192                 ;;
3193         esac
3194
3195         if test -n "$cf_try_cflags"
3196         then
3197 cat > conftest.$ac_ext <<EOF
3198 #line __oline__ "${as_me:-configure}"
3199 #include <stdio.h>
3200 int main(int argc, char *argv[[]])
3201 {
3202         printf("hello\n");
3203         return (argv[[argc-1]] == 0) ;
3204 }
3205 EOF
3206                 cf_save_CFLAGS="$CFLAGS"
3207                 for cf_opt in $cf_try_cflags
3208                 do
3209                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
3210                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
3211                         if AC_TRY_EVAL(ac_compile); then
3212                                 AC_MSG_RESULT(yes)
3213                                 cf_save_CFLAGS="$CFLAGS"
3214                         else
3215                                 AC_MSG_RESULT(no)
3216                         fi
3217                 done
3218                 CFLAGS="$cf_save_CFLAGS"
3219         fi
3220
3221
3222         # RPATH_LIST is a colon-separated list of directories
3223         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
3224         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
3225
3226         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
3227
3228         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
3229         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
3230
3231         AC_SUBST(CC_SHARED_OPTS)
3232         AC_SUBST(LD_RPATH_OPT)
3233         AC_SUBST(LD_SHARED_OPTS)
3234         AC_SUBST(MK_SHARED_LIB)
3235         AC_SUBST(RM_SHARED_OPTS)
3236
3237         AC_SUBST(LINK_PROGS)
3238         AC_SUBST(LINK_TESTS)
3239
3240         AC_SUBST(EXTRA_LDFLAGS)
3241         AC_SUBST(LOCAL_LDFLAGS)
3242         AC_SUBST(LOCAL_LDFLAGS2)
3243
3244         AC_SUBST(INSTALL_LIB)
3245         AC_SUBST(RPATH_LIST)
3246 ])dnl
3247 dnl ---------------------------------------------------------------------------
3248 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
3249 dnl ----------------
3250 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
3251 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
3252 dnl option.
3253 dnl
3254 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
3255 dnl If missing, use "rel".
3256 define([CF_SHARED_SONAME],
3257 [
3258         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
3259         if test "$cf_cv_shlib_version" = rel; then
3260                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
3261         else
3262                 cf_cv_shared_soname='`basename $[@]`'
3263         fi
3264 ])
3265 dnl ---------------------------------------------------------------------------
3266 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
3267 dnl --------------
3268 dnl     Remove "-g" option from the compiler options
3269 AC_DEFUN([CF_STRIP_G_OPT],
3270 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
3271 dnl ---------------------------------------------------------------------------
3272 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
3273 dnl --------------
3274 dnl Construct a search-list for a nonstandard header/lib-file
3275 dnl     $1 = the variable to return as result
3276 dnl     $2 = the package name
3277 dnl     $3 = the subdirectory, e.g., bin, include or lib
3278 AC_DEFUN([CF_SUBDIR_PATH],
3279 [
3280 $1=
3281
3282 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
3283 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
3284 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
3285 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
3286 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
3287 ])dnl
3288 dnl ---------------------------------------------------------------------------
3289 dnl CF_TERM_HEADER version: 3 updated: 2012/10/06 08:57:51
3290 dnl --------------
3291 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
3292 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
3293 dnl but some packagers change this, breaking various applications.
3294 AC_DEFUN([CF_TERM_HEADER],[
3295 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
3296 case ${cf_cv_ncurses_header} in #(vi
3297 */ncurses.h|*/ncursesw.h) #(vi
3298         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
3299         ;;
3300 *)
3301         cf_term_header=term.h
3302         ;;
3303 esac
3304
3305 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
3306 do
3307 AC_TRY_COMPILE([#include <stdio.h>
3308 #include <${cf_cv_ncurses_header:-curses.h}>
3309 #include <$cf_test>
3310 ],[int x = auto_left_margin],[
3311         cf_cv_term_header="$cf_test"],[
3312         cf_cv_term_header=unknown
3313         ])
3314         test "$cf_cv_term_header" != unknown && break
3315 done
3316 ])
3317
3318 # Set definitions to allow ifdef'ing to accommodate subdirectories
3319
3320 case $cf_cv_term_header in # (vi
3321 *term.h)
3322         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
3323         ;;
3324 esac
3325
3326 case $cf_cv_term_header in # (vi
3327 ncurses/term.h) #(vi
3328         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
3329         ;;
3330 ncursesw/term.h)
3331         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
3332         ;;
3333 esac
3334 ])dnl
3335 dnl ---------------------------------------------------------------------------
3336 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
3337 dnl ---------------
3338 dnl Define a top_builddir symbol, for applications that need an absolute path.
3339 AC_DEFUN([CF_TOP_BUILDDIR],
3340 [
3341 top_builddir=ifelse($1,,`pwd`,$1)
3342 AC_SUBST(top_builddir)
3343 ])dnl
3344 dnl ---------------------------------------------------------------------------
3345 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
3346 dnl -------------------
3347 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
3348 dnl can define it successfully.
3349 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
3350 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
3351         AC_TRY_COMPILE([
3352 #include <stdlib.h>
3353 #include <string.h>
3354 #include <sys/types.h>
3355 ],[
3356 #ifndef _XOPEN_SOURCE
3357 make an error
3358 #endif],
3359         [cf_cv_xopen_source=no],
3360         [cf_save="$CPPFLAGS"
3361          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3362          AC_TRY_COMPILE([
3363 #include <stdlib.h>
3364 #include <string.h>
3365 #include <sys/types.h>
3366 ],[
3367 #ifdef _XOPEN_SOURCE
3368 make an error
3369 #endif],
3370         [cf_cv_xopen_source=no],
3371         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
3372         CPPFLAGS="$cf_save"
3373         ])
3374 ])
3375
3376 if test "$cf_cv_xopen_source" != no ; then
3377         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
3378         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
3379         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
3380         CF_ADD_CFLAGS($cf_temp_xopen_source)
3381 fi
3382 ])
3383 dnl ---------------------------------------------------------------------------
3384 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
3385 dnl --------
3386 dnl Make an uppercase version of a variable
3387 dnl $1=uppercase($2)
3388 AC_DEFUN([CF_UPPER],
3389 [
3390 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
3391 ])dnl
3392 dnl ---------------------------------------------------------------------------
3393 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
3394 dnl -----------
3395 dnl Check for multibyte support, and if not found, utf8 compatibility library
3396 AC_DEFUN([CF_UTF8_LIB],
3397 [
3398 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
3399         cf_save_LIBS="$LIBS"
3400         AC_TRY_LINK([
3401 #include <stdlib.h>],[putwc(0,0);],
3402         [cf_cv_utf8_lib=yes],
3403         [CF_FIND_LINKAGE([
3404 #include <libutf8.h>],[putwc(0,0);],utf8,
3405                 [cf_cv_utf8_lib=add-on],
3406                 [cf_cv_utf8_lib=no])
3407 ])])
3408
3409 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
3410 # ncurses/ncursesw:
3411 if test "$cf_cv_utf8_lib" = "add-on" ; then
3412         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
3413         CF_ADD_INCDIR($cf_cv_header_path_utf8)
3414         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
3415         CF_ADD_LIBS($cf_cv_library_file_utf8)
3416 fi
3417 ])dnl
3418 dnl ---------------------------------------------------------------------------
3419 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
3420 dnl ----------
3421 dnl Use AC_VERBOSE w/o the warnings
3422 AC_DEFUN([CF_VERBOSE],
3423 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
3424 CF_MSG_LOG([$1])
3425 ])dnl
3426 dnl ---------------------------------------------------------------------------
3427 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
3428 dnl ---------------
3429 dnl Check for compiler-support for weak symbols.
3430 dnl This works with "recent" gcc.
3431 AC_DEFUN([CF_WEAK_SYMBOLS],[
3432 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
3433
3434 AC_TRY_COMPILE([
3435 #include <stdio.h>],
3436 [
3437 #if defined(__GNUC__)
3438 #  if defined __USE_ISOC99
3439 #    define _cat_pragma(exp)    _Pragma(#exp)
3440 #    define _weak_pragma(exp)   _cat_pragma(weak name)
3441 #  else
3442 #    define _weak_pragma(exp)
3443 #  endif
3444 #  define _declare(name)        __extension__ extern __typeof__(name) name
3445 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
3446 #endif
3447
3448 weak_symbol(fopen);
3449 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
3450 ])
3451 ])dnl
3452 dnl ---------------------------------------------------------------------------
3453 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
3454 dnl --------------------
3455 dnl Command-line option to specify the Ada95 compiler.
3456 AC_DEFUN([CF_WITH_ADA_COMPILER],[
3457 AC_MSG_CHECKING(for ada-compiler)
3458 AC_ARG_WITH(ada-compiler,
3459         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
3460         [cf_ada_compiler=$withval],
3461         [cf_ada_compiler=gnatmake])
3462 AC_SUBST(cf_ada_compiler)
3463 AC_MSG_RESULT($cf_ada_compiler)
3464 ])dnl
3465 dnl ---------------------------------------------------------------------------
3466 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
3467 dnl -------------------
3468 dnl Command-line option to specify where Ada includes will install.
3469 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
3470 AC_MSG_CHECKING(for ada-include)
3471 CF_WITH_PATH(ada-include,
3472    [  --with-ada-include=DIR  Ada includes are in DIR],
3473    ADA_INCLUDE,
3474    PREFIX/share/ada/adainclude,
3475    [$]prefix/share/ada/adainclude)
3476 AC_SUBST(ADA_INCLUDE)
3477 AC_MSG_RESULT($ADA_INCLUDE)
3478 ])dnl
3479 dnl ---------------------------------------------------------------------------
3480 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
3481 dnl -------------------
3482 dnl Command-line option to specify where Ada objects will install.
3483 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
3484 AC_MSG_CHECKING(for ada-objects)
3485 CF_WITH_PATH(ada-objects,
3486    [  --with-ada-objects=DIR  Ada objects are in DIR],
3487    ADA_OBJECTS,
3488    PREFIX/lib/ada/adalib,
3489    [$]prefix/lib/ada/adalib)
3490 AC_SUBST(ADA_OBJECTS)
3491 AC_MSG_RESULT($ADA_OBJECTS)
3492 ])dnl
3493 dnl ---------------------------------------------------------------------------
3494 dnl CF_WITH_ADA_SHAREDLIB version: 4 updated: 2014/05/31 21:08:37
3495 dnl ---------------------
3496 dnl Command-line option to specify if an Ada95 shared-library should be built,
3497 dnl and optionally what its soname should be.
3498 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
3499 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
3500 AC_ARG_WITH(ada-sharedlib,
3501         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
3502         [with_ada_sharedlib=$withval],
3503         [with_ada_sharedlib=no])
3504 AC_MSG_RESULT($with_ada_sharedlib)
3505
3506 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
3507 MAKE_ADA_SHAREDLIB="#"
3508
3509 if test "x$with_ada_sharedlib" != xno
3510 then
3511         MAKE_ADA_SHAREDLIB=
3512         if test "x$with_ada_sharedlib" != xyes
3513         then
3514                 ADA_SHAREDLIB="$with_ada_sharedlib"
3515         fi
3516 fi
3517
3518 AC_SUBST(ADA_SHAREDLIB)
3519 AC_SUBST(MAKE_ADA_SHAREDLIB)
3520 ])dnl
3521 dnl ---------------------------------------------------------------------------
3522 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3523 dnl ------------------
3524 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3525 dnl libraries.
3526 AC_DEFUN([CF_WITH_CURSES_DIR],[
3527
3528 AC_MSG_CHECKING(for specific curses-directory)
3529 AC_ARG_WITH(curses-dir,
3530         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3531         [cf_cv_curses_dir=$withval],
3532         [cf_cv_curses_dir=no])
3533 AC_MSG_RESULT($cf_cv_curses_dir)
3534
3535 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3536 then
3537         CF_PATH_SYNTAX(withval)
3538         if test -d "$cf_cv_curses_dir"
3539         then
3540                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3541                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3542         fi
3543 fi
3544 ])dnl
3545 dnl ---------------------------------------------------------------------------
3546 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
3547 dnl ------------------
3548 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
3549 dnl "lib" prefix, e.g., because it used the dll naming convention.
3550 dnl
3551 dnl $1 = variable to set
3552 AC_DEFUN([CF_WITH_LIB_PREFIX],
3553 [
3554 AC_MSG_CHECKING(if you want to have a library-prefix)
3555 AC_ARG_WITH(lib-prefix,
3556         [  --with-lib-prefix       override library-prefix],
3557         [with_lib_prefix=$withval],
3558         [with_lib_prefix=auto])
3559 AC_MSG_RESULT($with_lib_prefix)
3560
3561 if test $with_lib_prefix = auto
3562 then
3563         CF_LIB_PREFIX($1)
3564 elif test $with_lib_prefix = no
3565 then
3566         LIB_PREFIX=
3567 else
3568         LIB_PREFIX=$with_lib_prefix
3569 fi
3570 ])dnl
3571 dnl ---------------------------------------------------------------------------
3572 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
3573 dnl ------------
3574 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
3575 dnl defaulting to yes/no.
3576 dnl
3577 dnl $1 = option name
3578 dnl $2 = help-text
3579 dnl $3 = environment variable to set
3580 dnl $4 = default value, shown in the help-message, must be a constant
3581 dnl $5 = default value, if it's an expression & cannot be in the help-message
3582 dnl
3583 AC_DEFUN([CF_WITH_PATH],
3584 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
3585 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
3586 if ifelse([$5],,true,[test -n "$5"]) ; then
3587 CF_PATH_SYNTAX(withval)
3588 fi
3589 eval $3="$withval"
3590 AC_SUBST($3)dnl
3591 ])dnl
3592 dnl ---------------------------------------------------------------------------
3593 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 2 updated: 2011/12/10 18:58:47
3594 dnl -------------------------
3595 dnl Allow the choice of the pkg-config library directory to be overridden.
3596 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
3597 if test "$PKG_CONFIG" != none ; then
3598         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
3599         AC_ARG_WITH(pkg-config-libdir,
3600                 [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
3601                 [PKG_CONFIG_LIBDIR=$withval],
3602                 [PKG_CONFIG_LIBDIR=yes])
3603
3604         case x$PKG_CONFIG_LIBDIR in #(vi
3605         x/*) #(vi
3606                 ;;
3607         xyes) #(vi
3608                 # look for the library directory using the same prefix as the executable
3609                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
3610                 case x`(arch) 2>/dev/null` in #(vi
3611                 *64) #(vi
3612                         for cf_config in $cf_path/share $cf_path/lib64 $cf_path/lib32 $cf_path/lib
3613                         do
3614                                 if test -d $cf_config/pkgconfig
3615                                 then
3616                                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
3617                                         break
3618                                 fi
3619                         done
3620                         ;;
3621                 *)
3622                         PKG_CONFIG_LIBDIR=$cf_path/lib/pkgconfig
3623                         ;;
3624                 esac
3625                 ;;
3626         *)
3627                 ;;
3628         esac
3629
3630         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
3631 fi
3632
3633 AC_SUBST(PKG_CONFIG_LIBDIR)
3634 ])dnl
3635 dnl ---------------------------------------------------------------------------
3636 dnl CF_WITH_PTHREAD version: 6 updated: 2012/10/06 17:41:51
3637 dnl ---------------
3638 dnl Check for POSIX thread library.
3639 AC_DEFUN([CF_WITH_PTHREAD],
3640 [
3641 AC_MSG_CHECKING(if you want to link with the pthread library)
3642 AC_ARG_WITH(pthread,
3643     [  --with-pthread          use POSIX thread library],
3644     [with_pthread=$withval],
3645     [with_pthread=no])
3646 AC_MSG_RESULT($with_pthread)
3647
3648 if test "$with_pthread" != no ; then
3649     AC_CHECK_HEADER(pthread.h,[
3650         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
3651
3652         for cf_lib_pthread in pthread c_r
3653         do
3654             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
3655             cf_save_LIBS="$LIBS"
3656             CF_ADD_LIB($cf_lib_pthread)
3657             AC_TRY_LINK([
3658 #include <pthread.h>
3659 ],[
3660                 int rc = pthread_create(0,0,0,0);
3661                 int r2 = pthread_mutexattr_settype(0, 0);
3662 ],[with_pthread=yes],[with_pthread=no])
3663             LIBS="$cf_save_LIBS"
3664             AC_MSG_RESULT($with_pthread)
3665             test "$with_pthread" = yes && break
3666         done
3667
3668         if test "$with_pthread" = yes ; then
3669             CF_ADD_LIB($cf_lib_pthread)
3670             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
3671         else
3672             AC_MSG_ERROR(Cannot link with pthread library)
3673         fi
3674     ])
3675 fi
3676 ])
3677 dnl ---------------------------------------------------------------------------
3678 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
3679 dnl ---------------
3680 dnl For testing, override the derived host system-type which is used to decide
3681 dnl things such as the linker commands used to build shared libraries.  This is
3682 dnl normally chosen automatically based on the type of system which you are
3683 dnl building on.  We use it for testing the configure script.
3684 dnl
3685 dnl This is different from the --host option: it is used only for testing parts
3686 dnl of the configure script which would not be reachable with --host since that
3687 dnl relies on the build environment being real, rather than mocked up.
3688 AC_DEFUN([CF_WITH_SYSTYPE],[
3689 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
3690 AC_ARG_WITH(system-type,
3691         [  --with-system-type=XXX  test: override derived host system-type],
3692 [AC_MSG_WARN(overriding system type to $withval)
3693         cf_cv_system_name=$withval
3694         host_os=$withval
3695 ])
3696 ])dnl
3697 dnl ---------------------------------------------------------------------------
3698 dnl CF_XOPEN_SOURCE version: 46 updated: 2014/02/09 19:30:15
3699 dnl ---------------
3700 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
3701 dnl or adapt to the vendor's definitions to get equivalent functionality,
3702 dnl without losing the common non-POSIX features.
3703 dnl
3704 dnl Parameters:
3705 dnl     $1 is the nominal value for _XOPEN_SOURCE
3706 dnl     $2 is the nominal value for _POSIX_C_SOURCE
3707 AC_DEFUN([CF_XOPEN_SOURCE],[
3708 AC_REQUIRE([AC_CANONICAL_HOST])
3709
3710 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
3711 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
3712 cf_xopen_source=
3713
3714 case $host_os in #(vi
3715 aix[[4-7]]*) #(vi
3716         cf_xopen_source="-D_ALL_SOURCE"
3717         ;;
3718 cygwin|msys) #(vi
3719         cf_XOPEN_SOURCE=600
3720         ;;
3721 darwin[[0-8]].*) #(vi
3722         cf_xopen_source="-D_APPLE_C_SOURCE"
3723         ;;
3724 darwin*) #(vi
3725         cf_xopen_source="-D_DARWIN_C_SOURCE"
3726         cf_XOPEN_SOURCE=
3727         ;;
3728 freebsd*|dragonfly*) #(vi
3729         # 5.x headers associate
3730         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
3731         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
3732         cf_POSIX_C_SOURCE=200112L
3733         cf_XOPEN_SOURCE=600
3734         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3735         ;;
3736 hpux11*) #(vi
3737         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
3738         ;;
3739 hpux*) #(vi
3740         cf_xopen_source="-D_HPUX_SOURCE"
3741         ;;
3742 irix[[56]].*) #(vi
3743         cf_xopen_source="-D_SGI_SOURCE"
3744         cf_XOPEN_SOURCE=
3745         ;;
3746 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
3747         CF_GNU_SOURCE
3748         ;;
3749 mirbsd*) #(vi
3750         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
3751         cf_XOPEN_SOURCE=
3752         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3753         ;;
3754 netbsd*) #(vi
3755         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
3756         ;;
3757 openbsd[[4-9]]*) #(vi
3758         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
3759         cf_xopen_source="-D_BSD_SOURCE"
3760         cf_XOPEN_SOURCE=600
3761         ;;
3762 openbsd*) #(vi
3763         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
3764         ;;
3765 osf[[45]]*) #(vi
3766         cf_xopen_source="-D_OSF_SOURCE"
3767         ;;
3768 nto-qnx*) #(vi
3769         cf_xopen_source="-D_QNX_SOURCE"
3770         ;;
3771 sco*) #(vi
3772         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
3773         ;;
3774 solaris2.*) #(vi
3775         cf_xopen_source="-D__EXTENSIONS__"
3776         cf_cv_xopen_source=broken
3777         ;;
3778 *)
3779         CF_TRY_XOPEN_SOURCE
3780         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3781         ;;
3782 esac
3783
3784 if test -n "$cf_xopen_source" ; then
3785         CF_ADD_CFLAGS($cf_xopen_source)
3786 fi
3787
3788 dnl In anything but the default case, we may have system-specific setting
3789 dnl which is still not guaranteed to provide all of the entrypoints that
3790 dnl _XOPEN_SOURCE would yield.
3791 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
3792         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
3793         AC_TRY_COMPILE([#include <stdlib.h>],[
3794 #ifndef _XOPEN_SOURCE
3795 make an error
3796 #endif],
3797         [cf_XOPEN_SOURCE_set=yes],
3798         [cf_XOPEN_SOURCE_set=no])
3799         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
3800         if test $cf_XOPEN_SOURCE_set = yes
3801         then
3802                 AC_TRY_COMPILE([#include <stdlib.h>],[
3803 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
3804 make an error
3805 #endif],
3806                 [cf_XOPEN_SOURCE_set_ok=yes],
3807                 [cf_XOPEN_SOURCE_set_ok=no])
3808                 if test $cf_XOPEN_SOURCE_set_ok = no
3809                 then
3810                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
3811                 fi
3812         else
3813                 CF_TRY_XOPEN_SOURCE
3814         fi
3815 fi
3816 ])