Ada95/aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2022,2023 Thomas E. Dickey                                *
   3 dnl Copyright 2010-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey
  31 dnl
  32 dnl $Id: aclocal.m4,v 1.202 2023/04/15 20:02:10 tom Exp $
  33 dnl Macros used in NCURSES Ada95 auto-configuration script.
  34 dnl
  35 dnl These macros are maintained separately from NCURSES.  The copyright on
  36 dnl this file applies to the aggregation of macros and does not affect use of
  37 dnl these macros in other applications.
  38 dnl
  39 dnl See these pages for additional information:
  40 dnl             https://invisible-island.net/autoconf/
  41 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  42 dnl
  43 dnl ---------------------------------------------------------------------------
  44 dnl ---------------------------------------------------------------------------
  45 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
  46 dnl ------------------
  47 dnl Conditionally generate script according to whether we're using a given autoconf.
  48 dnl
  49 dnl $1 = version to compare against
  50 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  51 dnl $3 = code to use if AC_ACVERSION is older than $1.
  52 define([CF_ACVERSION_CHECK],
  53 [
  54 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
  55 ifdef([m4_version_compare],
  56 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  57 [CF_ACVERSION_COMPARE(
  58 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  59 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  60 dnl ---------------------------------------------------------------------------
  61 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  62 dnl --------------------
  63 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  64 dnl                      MAJOR2, MINOR2, TERNARY2,
  65 dnl                      PRINTABLE2, not FOUND, FOUND)
  66 define([CF_ACVERSION_COMPARE],
  67 [ifelse(builtin([eval], [$2 < $5]), 1,
  68 [ifelse([$8], , ,[$8])],
  69 [ifelse([$9], , ,[$9])])])dnl
  70 dnl ---------------------------------------------------------------------------
  71 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
  72 dnl -------------------
  73 dnl Construct the list of include-options for the C programs in the Ada95
  74 dnl binding.
  75 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  76 [
  77 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  78 if test "$srcdir" != "."; then
  79         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  80 fi
  81 if test "$GCC" != yes; then
  82         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  83 elif test "$includedir" != "/usr/include"; then
  84         if test "$includedir" = '${prefix}/include' ; then
  85                 if test x$prefix != x/usr ; then
  86                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  87                 fi
  88         else
  89                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  90         fi
  91 fi
  92 AC_SUBST(ACPPFLAGS)
  93 ])dnl
  94 dnl ---------------------------------------------------------------------------
  95 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
  96 dnl ---------------
  97 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
  98 AC_DEFUN([CF_ADD_ADAFLAGS],[
  99         ADAFLAGS="$ADAFLAGS $1"
 100         AC_SUBST(ADAFLAGS)
 101 ])dnl
 102 dnl ---------------------------------------------------------------------------
 103 dnl CF_ADD_CFLAGS version: 15 updated: 2020/12/31 10:54:15
 104 dnl -------------
 105 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 106 dnl $1 = flags to add
 107 dnl $2 = if given makes this macro verbose.
 108 dnl
 109 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 110 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 111 dnl confused by the quotes (which require backslashes to keep them usable).
 112 AC_DEFUN([CF_ADD_CFLAGS],
 113 [
 114 cf_fix_cppflags=no
 115 cf_new_cflags=
 116 cf_new_cppflags=
 117 cf_new_extra_cppflags=
 118
 119 for cf_add_cflags in $1
 120 do
 121 case "$cf_fix_cppflags" in
 122 (no)
 123         case "$cf_add_cflags" in
 124         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 125                 case "$cf_add_cflags" in
 126                 (-D*)
 127                         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 128
 129                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 130                                 && test -z "${cf_tst_cflags}" \
 131                                 && cf_fix_cppflags=yes
 132
 133                         if test "$cf_fix_cppflags" = yes ; then
 134                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 135                                 continue
 136                         elif test "${cf_tst_cflags}" = "\"'" ; then
 137                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 138                                 continue
 139                         fi
 140                         ;;
 141                 esac
 142                 case "$CPPFLAGS" in
 143                 (*$cf_add_cflags)
 144                         ;;
 145                 (*)
 146                         case "$cf_add_cflags" in
 147                         (-D*)
 148                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 149                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 150                                 ;;
 151                         esac
 152                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 153                         ;;
 154                 esac
 155                 ;;
 156         (*)
 157                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 158                 ;;
 159         esac
 160         ;;
 161 (yes)
 162         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 163
 164         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^[[^"]]*"'\''//'`
 165
 166         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 167                 && test -z "${cf_tst_cflags}" \
 168                 && cf_fix_cppflags=no
 169         ;;
 170 esac
 171 done
 172
 173 if test -n "$cf_new_cflags" ; then
 174         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 175         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 176 fi
 177
 178 if test -n "$cf_new_cppflags" ; then
 179         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 180         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 181 fi
 182
 183 if test -n "$cf_new_extra_cppflags" ; then
 184         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 185         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 186 fi
 187
 188 AC_SUBST(EXTRA_CPPFLAGS)
 189
 190 ])dnl
 191 dnl ---------------------------------------------------------------------------
 192 dnl CF_ADD_INCDIR version: 17 updated: 2021/09/04 06:35:04
 193 dnl -------------
 194 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it is
 195 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 196 dnl but old versions (and some misinstalled ones) need that.  To make things
 197 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 198 dnl the include-path).
 199 AC_DEFUN([CF_ADD_INCDIR],
 200 [
 201 if test -n "$1" ; then
 202   for cf_add_incdir in $1
 203   do
 204         while test "$cf_add_incdir" != /usr/include
 205         do
 206           if test -d "$cf_add_incdir"
 207           then
 208                 cf_have_incdir=no
 209                 if test -n "$CFLAGS$CPPFLAGS" ; then
 210                   # a loop is needed to ensure we can add subdirs of existing dirs
 211                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 212                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 213                           cf_have_incdir=yes; break
 214                         fi
 215                   done
 216                 fi
 217
 218                 if test "$cf_have_incdir" = no ; then
 219                   if test "$cf_add_incdir" = /usr/local/include ; then
 220                         if test "$GCC" = yes
 221                         then
 222                           cf_save_CPPFLAGS=$CPPFLAGS
 223                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 224                           AC_TRY_COMPILE([#include <stdio.h>],
 225                                   [printf("Hello")],
 226                                   [],
 227                                   [cf_have_incdir=yes])
 228                           CPPFLAGS=$cf_save_CPPFLAGS
 229                         fi
 230                   fi
 231                 fi
 232
 233                 if test "$cf_have_incdir" = no ; then
 234                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 235                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 236
 237                   cf_top_incdir=`echo "$cf_add_incdir" | sed -e 's%/include/.*$%/include%'`
 238                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 239                   cf_add_incdir="$cf_top_incdir"
 240                 else
 241                   break
 242                 fi
 243           else
 244                 break
 245           fi
 246         done
 247   done
 248 fi
 249 ])dnl
 250 dnl ---------------------------------------------------------------------------
 251 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 252 dnl ----------
 253 dnl Add a library, used to enforce consistency.
 254 dnl
 255 dnl $1 = library to add, without the "-l"
 256 dnl $2 = variable to update (default $LIBS)
 257 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 258 dnl ---------------------------------------------------------------------------
 259 dnl CF_ADD_LIBDIR version: 11 updated: 2020/12/31 20:19:42
 260 dnl -------------
 261 dnl     Adds to the library-path
 262 dnl
 263 dnl     Some machines have trouble with multiple -L options.
 264 dnl
 265 dnl $1 is the (list of) directory(s) to add
 266 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 267 dnl
 268 AC_DEFUN([CF_ADD_LIBDIR],
 269 [
 270 if test -n "$1" ; then
 271         for cf_add_libdir in $1
 272         do
 273                 if test "$cf_add_libdir" = /usr/lib ; then
 274                         :
 275                 elif test -d "$cf_add_libdir"
 276                 then
 277                         cf_have_libdir=no
 278                         if test -n "$LDFLAGS$LIBS" ; then
 279                                 # a loop is needed to ensure we can add subdirs of existing dirs
 280                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 281                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 282                                                 cf_have_libdir=yes; break
 283                                         fi
 284                                 done
 285                         fi
 286                         if test "$cf_have_libdir" = no ; then
 287                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 288                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 289                         fi
 290                 fi
 291         done
 292 fi
 293 ])dnl
 294 dnl ---------------------------------------------------------------------------
 295 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
 296 dnl -----------
 297 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 298 dnl prepended to an existing list, since their dependencies are assumed to
 299 dnl already exist in the list.
 300 dnl
 301 dnl $1 = libraries to add, with the "-l", etc.
 302 dnl $2 = variable to update (default $LIBS)
 303 AC_DEFUN([CF_ADD_LIBS],[
 304 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
 305 # reverse order
 306 cf_add_0lib=
 307 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
 308 # filter duplicates
 309 for cf_add_1lib in $cf_add_0lib; do
 310         for cf_add_2lib in $cf_add_libs; do
 311                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
 312                         cf_add_1lib=
 313                         break
 314                 fi
 315         done
 316         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
 317 done
 318 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 319 ])dnl
 320 dnl ---------------------------------------------------------------------------
 321 dnl CF_ADD_SUBDIR_PATH version: 5 updated: 2020/12/31 20:19:42
 322 dnl ------------------
 323 dnl Append to a search-list for a nonstandard header/lib-file
 324 dnl     $1 = the variable to return as result
 325 dnl     $2 = the package name
 326 dnl     $3 = the subdirectory, e.g., bin, include or lib
 327 dnl $4 = the directory under which we will test for subdirectories
 328 dnl $5 = a directory that we do not want $4 to match
 329 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 330 [
 331 test "x$4" != "x$5" && \
 332 test -d "$4" && \
 333 ifelse([$5],NONE,,[{ test -z "$5" || test "x$5" = xNONE || test "x$4" != "x$5"; } &&]) {
 334         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 335         test -d "$4/$3" &&          $1="[$]$1 $4/$3"
 336         test -d "$4/$3/$2" &&       $1="[$]$1 $4/$3/$2"
 337         test -d "$4/$3/$2/$3" &&    $1="[$]$1 $4/$3/$2/$3"
 338         test -d "$4/$2/$3" &&       $1="[$]$1 $4/$2/$3"
 339         test -d "$4/$2/$3/$2" &&    $1="[$]$1 $4/$2/$3/$2"
 340 }
 341 ])dnl
 342 dnl ---------------------------------------------------------------------------
 343 dnl CF_APPEND_CFLAGS version: 3 updated: 2021/09/05 17:25:40
 344 dnl ----------------
 345 dnl Use CF_ADD_CFLAGS after first checking for potential redefinitions.
 346 dnl $1 = flags to add
 347 dnl $2 = if given makes this macro verbose.
 348 define([CF_APPEND_CFLAGS],
 349 [
 350 for cf_add_cflags in $1
 351 do
 352         case "x$cf_add_cflags" in
 353         (x-[[DU]]*)
 354                 CF_REMOVE_CFLAGS($cf_add_cflags,CFLAGS,[$2])
 355                 CF_REMOVE_CFLAGS($cf_add_cflags,CPPFLAGS,[$2])
 356                 ;;
 357         esac
 358         CF_ADD_CFLAGS([$cf_add_cflags],[$2])
 359 done
 360 ])dnl
 361 dnl ---------------------------------------------------------------------------
 362 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 363 dnl --------------
 364 dnl use this macro for appending text without introducing an extra blank at
 365 dnl the beginning
 366 define([CF_APPEND_TEXT],
 367 [
 368         test -n "[$]$1" && $1="[$]$1 "
 369         $1="[$]{$1}$2"
 370 ])dnl
 371 dnl ---------------------------------------------------------------------------
 372 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 373 dnl --------------
 374 dnl Allow user to disable a normally-on option.
 375 AC_DEFUN([CF_ARG_DISABLE],
 376 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 377 dnl ---------------------------------------------------------------------------
 378 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 379 dnl -------------
 380 dnl Allow user to enable a normally-off option.
 381 AC_DEFUN([CF_ARG_ENABLE],
 382 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 383 dnl ---------------------------------------------------------------------------
 384 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 385 dnl -------------
 386 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 387 dnl values.
 388 dnl
 389 dnl Parameters:
 390 dnl $1 = option name
 391 dnl $2 = help-string
 392 dnl $3 = action to perform if option is not default
 393 dnl $4 = action if perform if option is default
 394 dnl $5 = default option value (either 'yes' or 'no')
 395 AC_DEFUN([CF_ARG_OPTION],
 396 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 397         if test "$enableval" != "$5" ; then
 398 ifelse([$3],,[    :]dnl
 399 ,[    $3]) ifelse([$4],,,[
 400         else
 401                 $4])
 402         fi],[enableval=$5 ifelse([$4],,,[
 403         $4
 404 ])dnl
 405 ])])dnl
 406 dnl ---------------------------------------------------------------------------
 407 dnl CF_AR_FLAGS version: 9 updated: 2021/01/01 13:31:04
 408 dnl -----------
 409 dnl Check for suitable "ar" (archiver) options for updating an archive.
 410 dnl
 411 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 412 dnl as well as a workaround for breakage of make's archive rules by the GNU
 413 dnl binutils "ar" program.
 414 AC_DEFUN([CF_AR_FLAGS],[
 415 AC_REQUIRE([CF_PROG_AR])
 416
 417 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 418         case "$cf_cv_system_name" in
 419         (*-msvc*)
 420                 cf_cv_ar_flags=''
 421                 cat >mk_static_lib.sh <<-EOF
 422                 #!$SHELL
 423                 MSVC_BIN="[$]AR"
 424                 out="\[$]1"
 425                 shift
 426                 exec \[$]MSVC_BIN -out:"\[$]out" \[$]@
 427                 EOF
 428                 chmod +x mk_static_lib.sh
 429                 AR=`pwd`/mk_static_lib.sh
 430                 ;;
 431         (*)
 432                 cf_cv_ar_flags=unknown
 433                 for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 434                 do
 435
 436                         # check if $ARFLAGS already contains this choice
 437                         if test "x$ARFLAGS" != "x" ; then
 438                                 cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 439                                 if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 440                                         cf_cv_ar_flags=
 441                                         break
 442                                 fi
 443                         fi
 444
 445                         rm -f "conftest.$ac_cv_objext"
 446                         rm -f conftest.a
 447
 448                         cat >"conftest.$ac_ext" <<EOF
 449 #line __oline__ "configure"
 450 int     testdata[[3]] = { 123, 456, 789 };
 451 EOF
 452                         if AC_TRY_EVAL(ac_compile) ; then
 453                                 echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 454                                 $AR $ARFLAGS "$cf_ar_flags" conftest.a "conftest.$ac_cv_objext" 2>&AC_FD_CC 1>/dev/null
 455                                 if test -f conftest.a ; then
 456                                         cf_cv_ar_flags="$cf_ar_flags"
 457                                         break
 458                                 fi
 459                         else
 460                                 CF_VERBOSE(cannot compile test-program)
 461                                 break
 462                         fi
 463                 done
 464                 rm -f conftest.a "conftest.$ac_ext" "conftest.$ac_cv_objext"
 465                 ;;
 466         esac
 467 ])
 468
 469 if test -n "$ARFLAGS" ; then
 470         if test -n "$cf_cv_ar_flags" ; then
 471                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 472         fi
 473 else
 474         ARFLAGS=$cf_cv_ar_flags
 475 fi
 476
 477 AC_SUBST(ARFLAGS)
 478 ])
 479 dnl ---------------------------------------------------------------------------
 480 dnl CF_BUILD_CC version: 11 updated: 2022/12/04 15:40:08
 481 dnl -----------
 482 dnl If we're cross-compiling, allow the user to override the tools and their
 483 dnl options.  The configure script is oriented toward identifying the host
 484 dnl compiler, etc., but we need a build compiler to generate parts of the
 485 dnl source.
 486 dnl
 487 dnl $1 = default for $CPPFLAGS
 488 dnl $2 = default for $LIBS
 489 AC_DEFUN([CF_BUILD_CC],[
 490 CF_ACVERSION_CHECK(2.52,,
 491         [AC_REQUIRE([CF_PROG_EXT])])
 492 if test "$cross_compiling" = yes ; then
 493
 494         # defaults that we might want to override
 495         : ${BUILD_CFLAGS:=''}
 496         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 497         : ${BUILD_LDFLAGS:=''}
 498         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 499         : ${BUILD_EXEEXT:='$x'}
 500         : ${BUILD_OBJEXT:='o'}
 501
 502         AC_ARG_WITH(build-cc,
 503                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 504                 [BUILD_CC="$withval"],
 505                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 506         AC_MSG_CHECKING(for native build C compiler)
 507         AC_MSG_RESULT($BUILD_CC)
 508
 509         AC_MSG_CHECKING(for native build C preprocessor)
 510         AC_ARG_WITH(build-cpp,
 511                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 512                 [BUILD_CPP="$withval"],
 513                 [BUILD_CPP='${BUILD_CC} -E'])
 514         AC_MSG_RESULT($BUILD_CPP)
 515
 516         AC_MSG_CHECKING(for native build C flags)
 517         AC_ARG_WITH(build-cflags,
 518                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 519                 [BUILD_CFLAGS="$withval"])
 520         AC_MSG_RESULT($BUILD_CFLAGS)
 521
 522         AC_MSG_CHECKING(for native build C preprocessor-flags)
 523         AC_ARG_WITH(build-cppflags,
 524                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 525                 [BUILD_CPPFLAGS="$withval"])
 526         AC_MSG_RESULT($BUILD_CPPFLAGS)
 527
 528         AC_MSG_CHECKING(for native build linker-flags)
 529         AC_ARG_WITH(build-ldflags,
 530                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 531                 [BUILD_LDFLAGS="$withval"])
 532         AC_MSG_RESULT($BUILD_LDFLAGS)
 533
 534         AC_MSG_CHECKING(for native build linker-libraries)
 535         AC_ARG_WITH(build-libs,
 536                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 537                 [BUILD_LIBS="$withval"])
 538         AC_MSG_RESULT($BUILD_LIBS)
 539
 540         # this assumes we're on Unix.
 541         BUILD_EXEEXT=
 542         BUILD_OBJEXT=o
 543
 544         : ${BUILD_CC:='${CC}'}
 545
 546         AC_MSG_CHECKING(if the build-compiler "$BUILD_CC" works)
 547
 548         cf_save_crossed=$cross_compiling
 549         cf_save_ac_link=$ac_link
 550         cross_compiling=no
 551         cf_build_cppflags=$BUILD_CPPFLAGS
 552         test "$cf_build_cppflags" = "#" && cf_build_cppflags=
 553         ac_link='$BUILD_CC -o "conftest$ac_exeext" $BUILD_CFLAGS $cf_build_cppflags $BUILD_LDFLAGS "conftest.$ac_ext" $BUILD_LIBS >&AS_MESSAGE_LOG_FD'
 554
 555         AC_TRY_RUN([#include <stdio.h>
 556                 int main(int argc, char *argv[])
 557                 {
 558                         ${cf_cv_main_return:-return}(argc < 0 || argv == 0 || argv[0] == 0);
 559                 }
 560         ],
 561                 cf_ok_build_cc=yes,
 562                 cf_ok_build_cc=no,
 563                 cf_ok_build_cc=unknown)
 564
 565         cross_compiling=$cf_save_crossed
 566         ac_link=$cf_save_ac_link
 567
 568         AC_MSG_RESULT($cf_ok_build_cc)
 569
 570         if test "$cf_ok_build_cc" != yes
 571         then
 572                 AC_MSG_ERROR([Cross-build requires two compilers.
 573 Use --with-build-cc to specify the native compiler.])
 574         fi
 575
 576 else
 577         : ${BUILD_CC:='${CC}'}
 578         : ${BUILD_CPP:='${CPP}'}
 579         : ${BUILD_CFLAGS:='${CFLAGS}'}
 580         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 581         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 582         : ${BUILD_LIBS:='${LIBS}'}
 583         : ${BUILD_EXEEXT:='$x'}
 584         : ${BUILD_OBJEXT:='o'}
 585 fi
 586
 587 AC_SUBST(BUILD_CC)
 588 AC_SUBST(BUILD_CPP)
 589 AC_SUBST(BUILD_CFLAGS)
 590 AC_SUBST(BUILD_CPPFLAGS)
 591 AC_SUBST(BUILD_LDFLAGS)
 592 AC_SUBST(BUILD_LIBS)
 593 AC_SUBST(BUILD_EXEEXT)
 594 AC_SUBST(BUILD_OBJEXT)
 595 ])dnl
 596 dnl ---------------------------------------------------------------------------
 597 dnl CF_C11_NORETURN version: 4 updated: 2023/02/18 17:41:25
 598 dnl ---------------
 599 AC_DEFUN([CF_C11_NORETURN],
 600 [
 601 AC_MSG_CHECKING(if you want to use C11 _Noreturn feature)
 602 CF_ARG_ENABLE(stdnoreturn,
 603         [  --enable-stdnoreturn    enable C11 _Noreturn feature for diagnostics],
 604         [enable_stdnoreturn=yes],
 605         [enable_stdnoreturn=no])
 606 AC_MSG_RESULT($enable_stdnoreturn)
 607
 608 if test $enable_stdnoreturn = yes; then
 609 AC_CACHE_CHECK([for C11 _Noreturn feature], cf_cv_c11_noreturn,
 610         [AC_TRY_COMPILE([
 611 $ac_includes_default
 612 #include <stdnoreturn.h>
 613 static _Noreturn void giveup(void) { exit(0); }
 614         ],
 615         [if (feof(stdin)) giveup()],
 616         cf_cv_c11_noreturn=yes,
 617         cf_cv_c11_noreturn=no)
 618         ])
 619 else
 620         cf_cv_c11_noreturn=no,
 621 fi
 622
 623 if test "$cf_cv_c11_noreturn" = yes; then
 624         AC_DEFINE(HAVE_STDNORETURN_H, 1,[Define if <stdnoreturn.h> header is available and working])
 625         AC_DEFINE_UNQUOTED(STDC_NORETURN,_Noreturn,[Define if C11 _Noreturn keyword is supported])
 626         HAVE_STDNORETURN_H=1
 627 else
 628         HAVE_STDNORETURN_H=0
 629 fi
 630
 631 AC_SUBST(HAVE_STDNORETURN_H)
 632 AC_SUBST(STDC_NORETURN)
 633 ])dnl
 634 dnl ---------------------------------------------------------------------------
 635 dnl CF_CC_ENV_FLAGS version: 11 updated: 2023/02/20 11:15:46
 636 dnl ---------------
 637 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 638 dnl into CC.  This will not help with broken scripts that wrap the compiler
 639 dnl with options, but eliminates a more common category of user confusion.
 640 dnl
 641 dnl In particular, it addresses the problem of being able to run the C
 642 dnl preprocessor in a consistent manner.
 643 dnl
 644 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 645 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 646 dnl outweighs that limitation.
 647 AC_DEFUN([CF_CC_ENV_FLAGS],
 648 [
 649 # This should have been defined by AC_PROG_CC
 650 : "${CC:=cc}"
 651
 652 AC_MSG_CHECKING(\$CFLAGS variable)
 653 case "x$CFLAGS" in
 654 (*-[[IUD]]*)
 655         AC_MSG_RESULT(broken)
 656         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 657         cf_flags="$CFLAGS"
 658         CFLAGS=
 659         for cf_arg in $cf_flags
 660         do
 661                 CF_ADD_CFLAGS($cf_arg)
 662         done
 663         ;;
 664 (*)
 665         AC_MSG_RESULT(ok)
 666         ;;
 667 esac
 668
 669 AC_MSG_CHECKING(\$CC variable)
 670 case "$CC" in
 671 (*[[\ \ ]]-*)
 672         AC_MSG_RESULT(broken)
 673         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 674         # humor him...
 675         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 676         cf_flags=`echo "$CC" | sed -e "s%^$cf_prog%%"`
 677         CC="$cf_prog"
 678         for cf_arg in $cf_flags
 679         do
 680                 case "x$cf_arg" in
 681                 (x-[[IUDfgOW]]*)
 682                         CF_ADD_CFLAGS($cf_arg)
 683                         ;;
 684                 (*)
 685                         CC="$CC $cf_arg"
 686                         ;;
 687                 esac
 688         done
 689         CF_VERBOSE(resulting CC: '$CC')
 690         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 691         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 692         ;;
 693 (*)
 694         AC_MSG_RESULT(ok)
 695         ;;
 696 esac
 697 ])dnl
 698 dnl ---------------------------------------------------------------------------
 699 dnl CF_CFG_DEFAULTS version: 16 updated: 2021/01/04 19:33:05
 700 dnl ---------------
 701 dnl Determine the default configuration into which we'll install ncurses.  This
 702 dnl can be overridden by the user's command-line options.  There's two items to
 703 dnl look for:
 704 dnl     1. the prefix (e.g., /usr)
 705 dnl     2. the header files (e.g., /usr/include/ncurses)
 706 dnl We'll look for a previous installation of ncurses and use the same defaults.
 707 dnl
 708 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 709 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 710 dnl programs from a vendor's.
 711 AC_DEFUN([CF_CFG_DEFAULTS],
 712 [AC_REQUIRE([AC_PROG_FGREP])dnl
 713
 714 AC_MSG_CHECKING(for prefix)
 715 if test "x$prefix" = "xNONE" ; then
 716         case "$cf_cv_system_name" in
 717                 # non-vendor systems don't have a conflict
 718         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 719                 prefix=/usr
 720                 ;;
 721         (*)     prefix=$ac_default_prefix
 722                 ;;
 723         esac
 724 fi
 725 AC_MSG_RESULT($prefix)
 726
 727 if test "x$prefix" = "xNONE" ; then
 728 AC_MSG_CHECKING(for default include-directory)
 729 test -n "$verbose" && echo 1>&AC_FD_MSG
 730 for cf_symbol in \
 731         "$includedir" \
 732         "$includedir/ncurses" \
 733         "$prefix/include" \
 734         "$prefix/include/ncurses" \
 735         /usr/local/include \
 736         /usr/local/include/ncurses \
 737         /usr/include \
 738         /usr/include/ncurses
 739 do
 740         cf_dir=`eval echo "$cf_symbol"`
 741         if test -f "$cf_dir/curses.h" ; then
 742         if ( ${FGREP-fgrep} NCURSES_VERSION "$cf_dir/curses.h" >/dev/null 2>&1 ) ; then
 743                 includedir="$cf_symbol"
 744                 test -n "$verbose"  && echo $ECHO_N "   found " 1>&AC_FD_MSG
 745                 break
 746         fi
 747         fi
 748         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 749 done
 750 AC_MSG_RESULT($includedir)
 751 fi
 752 ])dnl
 753 dnl ---------------------------------------------------------------------------
 754 dnl CF_CHECK_CACHE version: 13 updated: 2020/12/31 10:54:15
 755 dnl --------------
 756 dnl Check if we're accidentally using a cache from a different machine.
 757 dnl Derive the system name, as a check for reusing the autoconf cache.
 758 dnl
 759 dnl If we've packaged config.guess and config.sub, run that (since it does a
 760 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 761 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 762 dnl which is useful in cross-compiles.
 763 dnl
 764 dnl Note: we would use $ac_config_sub, but that is one of the places where
 765 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 766 AC_DEFUN([CF_CHECK_CACHE],
 767 [
 768 if test -f "$srcdir/config.guess" || test -f "$ac_aux_dir/config.guess" ; then
 769         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 770         system_name="$host_os"
 771 else
 772         system_name="`(uname -s -r) 2>/dev/null`"
 773         if test -z "$system_name" ; then
 774                 system_name="`(hostname) 2>/dev/null`"
 775         fi
 776 fi
 777 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 778 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 779
 780 test -z "$system_name" && system_name="$cf_cv_system_name"
 781 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 782
 783 if test ".$system_name" != ".$cf_cv_system_name" ; then
 784         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 785         AC_MSG_ERROR("Please remove config.cache and try again.")
 786 fi
 787 ])dnl
 788 dnl ---------------------------------------------------------------------------
 789 dnl CF_CHECK_GNAT_VERSION version: 4 updated: 2021/01/01 13:31:04
 790 dnl ---------------------
 791 AC_DEFUN([CF_CHECK_GNAT_VERSION],
 792 [
 793 AC_REQUIRE([CF_GNAT_VERSION])
 794 case "$cf_cv_gnat_version" in
 795 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
 796         cf_cv_prog_gnat_correct=yes
 797         ;;
 798 (*)
 799         AC_MSG_WARN(Unsupported GNAT version $cf_cv_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
 800         cf_cv_prog_gnat_correct=no
 801         ;;
 802 esac
 803 ])
 804 dnl ---------------------------------------------------------------------------
 805 dnl CF_CHECK_LIBSSP version: 1 updated: 2021/10/30 10:40:19
 806 dnl ---------------
 807 dnl Check if libssp is needed, e.g., to work around misconfigured libraries
 808 dnl used in cross-compiling to MinGW.
 809 AC_DEFUN([CF_CHECK_LIBSSP],[
 810 AC_CACHE_CHECK(if ssp library is needed,cf_cv_need_libssp,[
 811 AC_TRY_LINK([
 812 #include <sys/types.h>
 813 #include <dirent.h>
 814 ],[
 815        DIR *dp = opendir(".");
 816 ],cf_cv_need_libssp=no,[
 817         cf_save_LIBS="$LIBS"
 818         LIBS="$LIBS -lssp"
 819         AC_TRY_LINK([
 820 #include <sys/types.h>
 821 #include <dirent.h>
 822         ],[
 823                    DIR *dp = opendir(".");
 824         ],cf_cv_need_libssp=yes,
 825           cf_cv_need_libssp=maybe)
 826         LIBS="$cf_save_LIBS"
 827 ])dnl
 828 ])
 829
 830 if test "x$cf_cv_need_libssp" = xyes
 831 then
 832         CF_ADD_LIB(ssp)
 833 fi
 834 ])dnl
 835 dnl ---------------------------------------------------------------------------
 836 dnl CF_CLANG_COMPILER version: 9 updated: 2023/02/18 17:41:25
 837 dnl -----------------
 838 dnl Check if the given compiler is really clang.  clang's C driver defines
 839 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 840 dnl not ignore some gcc options.
 841 dnl
 842 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 843 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 844 dnl the wrappers for gcc and g++ warnings.
 845 dnl
 846 dnl $1 = GCC (default) or GXX
 847 dnl $2 = CLANG_COMPILER (default)
 848 dnl $3 = CFLAGS (default) or CXXFLAGS
 849 AC_DEFUN([CF_CLANG_COMPILER],[
 850 ifelse([$2],,CLANG_COMPILER,[$2])=no
 851
 852 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 853         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 854         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 855         AC_TRY_COMPILE([],[
 856 #ifdef __clang__
 857 #else
 858 #error __clang__ is not defined
 859 #endif
 860 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 861 ],[])
 862         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 863         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 864 fi
 865
 866 CLANG_VERSION=none
 867
 868 if test "x$ifelse([$2],,CLANG_COMPILER,[$2])" = "xyes" ; then
 869         case "$CC" in
 870         (c[[1-9]][[0-9]]|*/c[[1-9]][[0-9]])
 871                 AC_MSG_WARN(replacing broken compiler alias $CC)
 872                 CFLAGS="$CFLAGS -std=`echo "$CC" | sed -e 's%.*/%%'`"
 873                 CC=clang
 874                 ;;
 875         esac
 876
 877         AC_MSG_CHECKING(version of $CC)
 878         CLANG_VERSION="`$CC --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(CLANG[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
 879         test -z "$CLANG_VERSION" && CLANG_VERSION=unknown
 880         AC_MSG_RESULT($CLANG_VERSION)
 881
 882         for cf_clang_opt in \
 883                 -Qunused-arguments \
 884                 -Wno-error=implicit-function-declaration
 885         do
 886                 AC_MSG_CHECKING(if option $cf_clang_opt works)
 887                 cf_save_CFLAGS="$CFLAGS"
 888                 CFLAGS="$CFLAGS $cf_clang_opt"
 889                 AC_TRY_LINK([
 890                         #include <stdio.h>],[
 891                         printf("hello!\\n");],[
 892                         cf_clang_optok=yes],[
 893                         cf_clang_optok=no])
 894                 AC_MSG_RESULT($cf_clang_optok)
 895                 CFLAGS="$cf_save_CFLAGS"
 896                 if test "$cf_clang_optok" = yes; then
 897                         CF_VERBOSE(adding option $cf_clang_opt)
 898                         CF_APPEND_TEXT(CFLAGS,$cf_clang_opt)
 899                 fi
 900         done
 901 fi
 902 ])
 903 dnl ---------------------------------------------------------------------------
 904 dnl CF_CONST_X_STRING version: 7 updated: 2021/06/07 17:39:17
 905 dnl -----------------
 906 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
 907 dnl character-strings.
 908 dnl
 909 dnl It is ambiguous because the specification accommodated the pre-ANSI
 910 dnl compilers bundled by more than one vendor in lieu of providing a standard C
 911 dnl compiler other than by costly add-ons.  Because of this, the specification
 912 dnl did not take into account the use of const for telling the compiler that
 913 dnl string literals would be in readonly memory.
 914 dnl
 915 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
 916 dnl let the compiler decide how to represent Xt's strings which were #define'd.
 917 dnl That does not solve the problem of using the block of Xt's strings which
 918 dnl are compiled into the library (and is less efficient than one might want).
 919 dnl
 920 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
 921 dnl when compiling the library and compiling using the library, to tell the
 922 dnl compiler that String is const.
 923 AC_DEFUN([CF_CONST_X_STRING],
 924 [
 925 AC_REQUIRE([AC_PATH_XTRA])
 926
 927 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
 928
 929 AC_TRY_COMPILE(
 930 [
 931 #include <stdlib.h>
 932 #include <X11/Intrinsic.h>
 933 ],
 934 [String foo = malloc(1); free((void*)foo)],[
 935
 936 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
 937         AC_TRY_COMPILE(
 938                 [
 939 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
 940 #undef  XTSTRINGDEFINES /* X11R5 and later */
 941 #include <stdlib.h>
 942 #include <X11/Intrinsic.h>
 943                 ],[String foo = malloc(1); *foo = 0],[
 944                         cf_cv_const_x_string=no
 945                 ],[
 946                         cf_cv_const_x_string=yes
 947                 ])
 948 ])
 949
 950 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
 951
 952 case "$cf_cv_const_x_string" in
 953 (no)
 954         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
 955         ;;
 956 (*)
 957         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
 958         ;;
 959 esac
 960
 961 ])
 962 ])dnl
 963 dnl ---------------------------------------------------------------------------
 964 dnl CF_CONST_X_STRING version: 7 updated: 2021/06/07 17:39:17
 965 dnl -----------------
 966 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
 967 dnl character-strings.
 968 dnl
 969 dnl It is ambiguous because the specification accommodated the pre-ANSI
 970 dnl compilers bundled by more than one vendor in lieu of providing a standard C
 971 dnl compiler other than by costly add-ons.  Because of this, the specification
 972 dnl did not take into account the use of const for telling the compiler that
 973 dnl string literals would be in readonly memory.
 974 dnl
 975 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
 976 dnl let the compiler decide how to represent Xt's strings which were #define'd.
 977 dnl That does not solve the problem of using the block of Xt's strings which
 978 dnl are compiled into the library (and is less efficient than one might want).
 979 dnl
 980 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
 981 dnl when compiling the library and compiling using the library, to tell the
 982 dnl compiler that String is const.
 983 AC_DEFUN([CF_CONST_X_STRING],
 984 [
 985 AC_REQUIRE([AC_PATH_XTRA])
 986
 987 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
 988
 989 AC_TRY_COMPILE(
 990 [
 991 #include <stdlib.h>
 992 #include <X11/Intrinsic.h>
 993 ],
 994 [String foo = malloc(1); free((void*)foo)],[
 995
 996 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
 997         AC_TRY_COMPILE(
 998                 [
 999 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
1000 #undef  XTSTRINGDEFINES /* X11R5 and later */
1001 #include <stdlib.h>
1002 #include <X11/Intrinsic.h>
1003                 ],[String foo = malloc(1); *foo = 0],[
1004                         cf_cv_const_x_string=no
1005                 ],[
1006                         cf_cv_const_x_string=yes
1007                 ])
1008 ])
1009
1010 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
1011
1012 case "$cf_cv_const_x_string" in
1013 (no)
1014         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
1015         ;;
1016 (*)
1017         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
1018         ;;
1019 esac
1020
1021 ])
1022 ])dnl
1023 dnl ---------------------------------------------------------------------------
1024 dnl CF_CURSES_HEADER version: 6 updated: 2022/12/02 20:06:52
1025 dnl ----------------
1026 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
1027 dnl variations of ncurses' installs.
1028 dnl
1029 dnl $1 = ncurses when looking for ncurses, or is empty
1030 AC_DEFUN([CF_CURSES_HEADER],[
1031 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
1032 cf_cv_ncurses_header=none
1033 for cf_header in \
1034         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
1035         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
1036 do
1037 AC_TRY_COMPILE([#include <${cf_header}>],
1038         [initscr(); endwin()],
1039         [cf_cv_ncurses_header=$cf_header; break],[])
1040 done
1041 ])
1042
1043 if test "$cf_cv_ncurses_header" = none ; then
1044         AC_MSG_ERROR(No curses header-files found)
1045 fi
1046
1047 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
1048 AC_CHECK_HEADERS($cf_cv_ncurses_header)
1049 ])dnl
1050 dnl ---------------------------------------------------------------------------
1051 dnl CF_DIRNAME version: 5 updated: 2020/12/31 20:19:42
1052 dnl ----------
1053 dnl "dirname" is not portable, so we fake it with a shell script.
1054 AC_DEFUN([CF_DIRNAME],[$1=`echo "$2" | sed -e 's%/[[^/]]*$%%'`])dnl
1055 dnl ---------------------------------------------------------------------------
1056 dnl CF_DISABLE_ECHO version: 14 updated: 2021/09/04 06:35:04
1057 dnl ---------------
1058 dnl You can always use "make -n" to see the actual options, but it is hard to
1059 dnl pick out/analyze warning messages when the compile-line is long.
1060 dnl
1061 dnl Sets:
1062 dnl     ECHO_LT - symbol to control if libtool is verbose
1063 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1064 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1065 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1066 dnl     ECHO_CC - symbol to put before any "cc" line
1067 dnl
1068 AC_DEFUN([CF_DISABLE_ECHO],[
1069 AC_MSG_CHECKING(if you want to see long compiling messages)
1070 CF_ARG_DISABLE(echo,
1071         [  --disable-echo          do not display "compiling" commands],
1072         [
1073         ECHO_LT='--silent'
1074         ECHO_LD='@echo linking [$]@;'
1075         RULE_CC='@echo compiling [$]<'
1076         SHOW_CC='@echo compiling [$]@'
1077         ECHO_CC='@'
1078 ],[
1079         ECHO_LT=''
1080         ECHO_LD=''
1081         RULE_CC=''
1082         SHOW_CC=''
1083         ECHO_CC=''
1084 ])
1085 AC_MSG_RESULT($enableval)
1086 AC_SUBST(ECHO_LT)
1087 AC_SUBST(ECHO_LD)
1088 AC_SUBST(RULE_CC)
1089 AC_SUBST(SHOW_CC)
1090 AC_SUBST(ECHO_CC)
1091 ])dnl
1092 dnl ---------------------------------------------------------------------------
1093 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1094 dnl ------------------------
1095 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1096 AC_MSG_CHECKING(if we want to use GNAT projects)
1097 CF_ARG_DISABLE(gnat-projects,
1098         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1099         [enable_gnat_projects=no],
1100         [enable_gnat_projects=yes])
1101 AC_MSG_RESULT($enable_gnat_projects)
1102 ])dnl
1103 dnl ---------------------------------------------------------------------------
1104 dnl CF_ENABLE_BROKEN_LINKER version: 2 updated: 2021/01/02 17:09:14
1105 dnl -----------------------
1106 dnl Some linkers cannot reference a data-only object.  Cygwin used to be one.
1107 dnl This usually follows CF_LINK_DATAONLY, but is not required in case we need
1108 dnl an unconditional feature.
1109 AC_DEFUN([CF_ENABLE_BROKEN_LINKER],[
1110
1111 AC_MSG_CHECKING(if you want broken-linker support code)
1112 AC_ARG_ENABLE(broken_linker,
1113         [  --enable-broken_linker  compile with broken-linker support code],
1114         [with_broken_linker=$enableval],
1115         [with_broken_linker=no])
1116 AC_MSG_RESULT($with_broken_linker)
1117
1118 : "${BROKEN_LINKER:=0}"
1119 if test "x$with_broken_linker" = xyes ; then
1120         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
1121         BROKEN_LINKER=1
1122 fi
1123 AC_SUBST(BROKEN_LINKER)
1124 ])dnl
1125 dnl ---------------------------------------------------------------------------
1126 dnl CF_ENABLE_WARNINGS version: 9 updated: 2021/01/05 19:40:50
1127 dnl ------------------
1128 dnl Configure-option to enable gcc warnings
1129 dnl
1130 dnl $1 = extra options to add, if supported
1131 dnl $2 = option for checking attributes.  By default, this is done when
1132 dnl      warnings are enabled.  For other values:
1133 dnl      yes: always do this, e.g., to use in generated library-headers
1134 dnl      no: never do this
1135 AC_DEFUN([CF_ENABLE_WARNINGS],[
1136 if test "$GCC" = yes || test "$GXX" = yes
1137 then
1138 CF_FIX_WARNINGS(CFLAGS)
1139 CF_FIX_WARNINGS(CPPFLAGS)
1140 CF_FIX_WARNINGS(LDFLAGS)
1141 AC_MSG_CHECKING(if you want to turn on gcc warnings)
1142 CF_ARG_ENABLE(warnings,
1143         [  --enable-warnings       test: turn on gcc compiler warnings],
1144         [enable_warnings=yes],
1145         [enable_warnings=no])
1146 AC_MSG_RESULT($enable_warnings)
1147 if test "$enable_warnings" = "yes"
1148 then
1149         ifelse($2,,[CF_GCC_ATTRIBUTES])
1150         CF_GCC_WARNINGS($1)
1151 fi
1152 ifelse($2,yes,[CF_GCC_ATTRIBUTES])
1153 fi
1154 ])dnl
1155 dnl ---------------------------------------------------------------------------
1156 dnl CF_FIND_LIBRARY version: 11 updated: 2021/01/02 09:31:20
1157 dnl ---------------
1158 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
1159 dnl prefer a standard location, and use -L options only if we do not find the
1160 dnl library in the standard library location(s).
1161 dnl     $1 = library name
1162 dnl     $2 = library class, usually the same as library name
1163 dnl     $3 = includes
1164 dnl     $4 = code fragment to compile/link
1165 dnl     $5 = corresponding function-name
1166 dnl     $6 = flag, nonnull if failure should not cause an error-exit
1167 dnl
1168 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
1169 dnl to use a -L option.
1170 AC_DEFUN([CF_FIND_LIBRARY],
1171 [
1172         eval 'cf_cv_have_lib_'"$1"'=no'
1173         cf_libdir=""
1174         AC_CHECK_FUNC($5,
1175                 eval 'cf_cv_have_lib_'"$1"'=yes',[
1176                 cf_save_LIBS="$LIBS"
1177                 AC_MSG_CHECKING(for $5 in -l$1)
1178                 LIBS="-l$1 $LIBS"
1179                 AC_TRY_LINK([$3],[$4],
1180                         [AC_MSG_RESULT(yes)
1181                          eval 'cf_cv_have_lib_'"$1"'=yes'
1182                         ],
1183                         [AC_MSG_RESULT(no)
1184                         CF_LIBRARY_PATH(cf_search,$2)
1185                         for cf_libdir in $cf_search
1186                         do
1187                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
1188                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
1189                                 AC_TRY_LINK([$3],[$4],
1190                                         [AC_MSG_RESULT(yes)
1191                                          eval 'cf_cv_have_lib_'"$1"'=yes'
1192                                          break],
1193                                         [AC_MSG_RESULT(no)
1194                                          LIBS="$cf_save_LIBS"])
1195                         done
1196                         ])
1197                 ])
1198 eval 'cf_found_library="[$]cf_cv_have_lib_'"$1"\"
1199 ifelse($6,,[
1200 if test "$cf_found_library" = no ; then
1201         AC_MSG_ERROR(Cannot link $1 library)
1202 fi
1203 ])
1204 ])dnl
1205 dnl ---------------------------------------------------------------------------
1206 dnl CF_FIND_LINKAGE version: 22 updated: 2020/12/31 20:19:42
1207 dnl ---------------
1208 dnl Find a library (specifically the linkage used in the code fragment),
1209 dnl searching for it if it is not already in the library path.
1210 dnl See also CF_ADD_SEARCHPATH.
1211 dnl
1212 dnl Parameters (4-on are optional):
1213 dnl     $1 = headers for library entrypoint
1214 dnl     $2 = code fragment for library entrypoint
1215 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1216 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1217 dnl     $5 = action to perform if not successful
1218 dnl     $6 = module name, if not the same as the library name
1219 dnl     $7 = extra libraries
1220 dnl
1221 dnl Sets these variables:
1222 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1223 dnl     $cf_cv_header_path_$3 - include-directory if needed
1224 dnl     $cf_cv_library_path_$3 - library-directory if needed
1225 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1226 AC_DEFUN([CF_FIND_LINKAGE],[
1227
1228 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1229 # will be set on completion of the AC_TRY_LINK below.
1230 cf_cv_header_path_$3=
1231 cf_cv_library_path_$3=
1232
1233 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1234
1235 cf_save_LIBS="$LIBS"
1236
1237 AC_TRY_LINK([$1],[$2],[
1238         cf_cv_find_linkage_$3=yes
1239         cf_cv_header_path_$3=/usr/include
1240         cf_cv_library_path_$3=/usr/lib
1241 ],[
1242
1243 LIBS="-l$3 $7 $cf_save_LIBS"
1244
1245 AC_TRY_LINK([$1],[$2],[
1246         cf_cv_find_linkage_$3=yes
1247         cf_cv_header_path_$3=/usr/include
1248         cf_cv_library_path_$3=/usr/lib
1249         cf_cv_library_file_$3="-l$3"
1250 ],[
1251         cf_cv_find_linkage_$3=no
1252         LIBS="$cf_save_LIBS"
1253
1254         CF_VERBOSE(find linkage for $3 library)
1255         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1256
1257         cf_save_CPPFLAGS="$CPPFLAGS"
1258         cf_test_CPPFLAGS="$CPPFLAGS"
1259
1260         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1261         for cf_cv_header_path_$3 in $cf_search
1262         do
1263                 if test -d "$cf_cv_header_path_$3" ; then
1264                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1265                         CPPFLAGS="$cf_save_CPPFLAGS"
1266                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
1267                         AC_TRY_COMPILE([$1],[$2],[
1268                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1269                                 cf_cv_find_linkage_$3=maybe
1270                                 cf_test_CPPFLAGS="$CPPFLAGS"
1271                                 break],[
1272                                 CPPFLAGS="$cf_save_CPPFLAGS"
1273                                 ])
1274                 fi
1275         done
1276
1277         if test "$cf_cv_find_linkage_$3" = maybe ; then
1278
1279                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1280
1281                 cf_save_LIBS="$LIBS"
1282                 cf_save_LDFLAGS="$LDFLAGS"
1283
1284                 ifelse([$6],,,[
1285                 CPPFLAGS="$cf_test_CPPFLAGS"
1286                 LIBS="-l$3 $7 $cf_save_LIBS"
1287                 AC_TRY_LINK([$1],[$2],[
1288                         CF_VERBOSE(... found $3 library in system)
1289                         cf_cv_find_linkage_$3=yes])
1290                         CPPFLAGS="$cf_save_CPPFLAGS"
1291                         LIBS="$cf_save_LIBS"
1292                         ])
1293
1294                 if test "$cf_cv_find_linkage_$3" != yes ; then
1295                         CF_LIBRARY_PATH(cf_search,$3)
1296                         for cf_cv_library_path_$3 in $cf_search
1297                         do
1298                                 if test -d "$cf_cv_library_path_$3" ; then
1299                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1300                                         CPPFLAGS="$cf_test_CPPFLAGS"
1301                                         LIBS="-l$3 $7 $cf_save_LIBS"
1302                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1303                                         AC_TRY_LINK([$1],[$2],[
1304                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1305                                         cf_cv_find_linkage_$3=yes
1306                                         cf_cv_library_file_$3="-l$3"
1307                                         break],[
1308                                         CPPFLAGS="$cf_save_CPPFLAGS"
1309                                         LIBS="$cf_save_LIBS"
1310                                         LDFLAGS="$cf_save_LDFLAGS"
1311                                         ])
1312                                 fi
1313                         done
1314                         CPPFLAGS="$cf_save_CPPFLAGS"
1315                         LDFLAGS="$cf_save_LDFLAGS"
1316                 fi
1317
1318         else
1319                 cf_cv_find_linkage_$3=no
1320         fi
1321         ],$7)
1322 ])
1323
1324 LIBS="$cf_save_LIBS"
1325
1326 if test "$cf_cv_find_linkage_$3" = yes ; then
1327 ifelse([$4],,[
1328         CF_ADD_INCDIR($cf_cv_header_path_$3)
1329         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1330         CF_ADD_LIB($3)
1331 ],[$4])
1332 else
1333 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1334 fi
1335 ])dnl
1336 dnl ---------------------------------------------------------------------------
1337 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1338 dnl -----------------
1339 dnl make ADAFLAGS consistent with CFLAGS
1340 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1341         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1342         case "$CFLAGS" in
1343         (*-g*)
1344                 CF_ADD_ADAFLAGS(-g)
1345                 ;;
1346         esac
1347         case "$CFLAGS" in
1348         (*-O*)
1349                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1350                 CF_ADD_ADAFLAGS($cf_O_flag)
1351                 ;;
1352         esac
1353         AC_MSG_RESULT($ADAFLAGS)
1354 ])dnl
1355 dnl ---------------------------------------------------------------------------
1356 dnl CF_FIX_WARNINGS version: 4 updated: 2021/12/16 18:22:31
1357 dnl ---------------
1358 dnl Warning flags do not belong in CFLAGS, CPPFLAGS, etc.  Any of gcc's
1359 dnl "-Werror" flags can interfere with configure-checks.  Those go into
1360 dnl EXTRA_CFLAGS.
1361 dnl
1362 dnl $1 = variable name to repair
1363 define([CF_FIX_WARNINGS],[
1364 if test "$GCC" = yes || test "$GXX" = yes
1365 then
1366         case [$]$1 in
1367         (*-Werror=*)
1368                 cf_temp_flags=
1369                 for cf_temp_scan in [$]$1
1370                 do
1371                         case "x$cf_temp_scan" in
1372                         (x-Werror=format*)
1373                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
1374                                 ;;
1375                         (x-Werror=*)
1376                                 CF_APPEND_TEXT(EXTRA_CFLAGS,$cf_temp_scan)
1377                                 ;;
1378                         (*)
1379                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
1380                                 ;;
1381                         esac
1382                 done
1383                 if test "x[$]$1" != "x$cf_temp_flags"
1384                 then
1385                         CF_VERBOSE(repairing $1: [$]$1)
1386                         $1="$cf_temp_flags"
1387                         CF_VERBOSE(... fixed [$]$1)
1388                         CF_VERBOSE(... extra $EXTRA_CFLAGS)
1389                 fi
1390                 ;;
1391         esac
1392 fi
1393 AC_SUBST(EXTRA_CFLAGS)
1394 ])dnl
1395 dnl ---------------------------------------------------------------------------
1396 dnl CF_FUNC_GETTIME version: 2 updated: 2023/02/25 08:45:56
1397 dnl ---------------
1398 dnl Check for gettimeofday or clock_gettime.  In 2023, the former is still more
1399 dnl widely supported, but "deprecated" (2008), so we will use the latter if it
1400 dnl is available, to reduce compiler warnings.
1401 AC_DEFUN([CF_FUNC_GETTIME],[
1402 AC_CACHE_CHECK(for clock_gettime,cf_cv_func_clock_gettime,[
1403                 AC_TRY_LINK([#include <time.h>],
1404                 [struct timespec ts;
1405                 int rc = clock_gettime(CLOCK_REALTIME, &ts); (void) rc; (void)ts],
1406                 [cf_cv_func_clock_gettime=yes],
1407                 [cf_cv_func_clock_gettime=no])
1408 ])
1409
1410 if test "$cf_cv_func_clock_gettime" = yes
1411 then
1412         AC_DEFINE(HAVE_CLOCK_GETTIME,1,[Define to 1 if we have clock_gettime function])
1413 else
1414 AC_CHECK_FUNC(gettimeofday,
1415         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1416
1417 AC_CHECK_LIB(bsd, gettimeofday,
1418         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1419         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1420 fi
1421 ])dnl
1422 dnl ---------------------------------------------------------------------------
1423 dnl CF_GCC_ATTRIBUTES version: 24 updated: 2021/03/20 12:00:25
1424 dnl -----------------
1425 dnl Test for availability of useful gcc __attribute__ directives to quiet
1426 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1427 dnl to documentation, unrecognized directives cause older compilers to barf.
1428 AC_DEFUN([CF_GCC_ATTRIBUTES],
1429 [AC_REQUIRE([AC_PROG_FGREP])dnl
1430 AC_REQUIRE([CF_C11_NORETURN])dnl
1431
1432 if test "$GCC" = yes || test "$GXX" = yes
1433 then
1434 cat > conftest.i <<EOF
1435 #ifndef GCC_PRINTF
1436 #define GCC_PRINTF 0
1437 #endif
1438 #ifndef GCC_SCANF
1439 #define GCC_SCANF 0
1440 #endif
1441 #ifndef GCC_NORETURN
1442 #define GCC_NORETURN /* nothing */
1443 #endif
1444 #ifndef GCC_UNUSED
1445 #define GCC_UNUSED /* nothing */
1446 #endif
1447 EOF
1448 if test "$GCC" = yes
1449 then
1450         AC_CHECKING([for $CC __attribute__ directives])
1451 cat > "conftest.$ac_ext" <<EOF
1452 #line __oline__ "${as_me:-configure}"
1453 #include <stdio.h>
1454 #include "confdefs.h"
1455 #include "conftest.h"
1456 #include "conftest.i"
1457 #if     GCC_PRINTF
1458 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1459 #else
1460 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1461 #endif
1462 #if     GCC_SCANF
1463 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1464 #else
1465 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1466 #endif
1467 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1468 extern GCC_NORETURN void oops(char *,...) GCC_PRINTFLIKE(1,2);
1469 extern GCC_NORETURN void foo(void);
1470 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
1471 EOF
1472         cf_printf_attribute=no
1473         cf_scanf_attribute=no
1474         for cf_attribute in scanf printf unused noreturn
1475         do
1476                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1477                 cf_directive="__attribute__(($cf_attribute))"
1478                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1479
1480                 case "$cf_attribute" in
1481                 (printf)
1482                         cf_printf_attribute=yes
1483                         cat >conftest.h <<EOF
1484 #define GCC_$cf_ATTRIBUTE 1
1485 EOF
1486                         ;;
1487                 (scanf)
1488                         cf_scanf_attribute=yes
1489                         cat >conftest.h <<EOF
1490 #define GCC_$cf_ATTRIBUTE 1
1491 EOF
1492                         ;;
1493                 (*)
1494                         cat >conftest.h <<EOF
1495 #define GCC_$cf_ATTRIBUTE $cf_directive
1496 EOF
1497                         ;;
1498                 esac
1499
1500                 if AC_TRY_EVAL(ac_compile); then
1501                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1502                         cat conftest.h >>confdefs.h
1503                         case "$cf_attribute" in
1504                         (noreturn)
1505                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1506                                 ;;
1507                         (printf)
1508                                 cf_value='/* nothing */'
1509                                 if test "$cf_printf_attribute" != no ; then
1510                                         cf_value='__attribute__((format(printf,fmt,var)))'
1511                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1512                                 fi
1513                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1514                                 ;;
1515                         (scanf)
1516                                 cf_value='/* nothing */'
1517                                 if test "$cf_scanf_attribute" != no ; then
1518                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1519                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1520                                 fi
1521                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1522                                 ;;
1523                         (unused)
1524                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1525                                 ;;
1526                         esac
1527                 fi
1528         done
1529 else
1530         ${FGREP-fgrep} define conftest.i >>confdefs.h
1531 fi
1532 rm -rf ./conftest*
1533 fi
1534 ])dnl
1535 dnl ---------------------------------------------------------------------------
1536 dnl CF_GCC_VERSION version: 9 updated: 2023/03/05 14:30:13
1537 dnl --------------
1538 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
1539 dnl compatible), attempt to determine if icc/clang is actually used.
1540 AC_DEFUN([CF_GCC_VERSION],[
1541 AC_REQUIRE([AC_PROG_CC])
1542 GCC_VERSION=none
1543 if test "$GCC" = yes ; then
1544         AC_MSG_CHECKING(version of $CC)
1545         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^[[^(]]*([[^)]][[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1546         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1547         AC_MSG_RESULT($GCC_VERSION)
1548 fi
1549 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1550 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1551 ])dnl
1552 dnl ---------------------------------------------------------------------------
1553 dnl CF_GCC_WARNINGS version: 41 updated: 2021/01/01 16:53:59
1554 dnl ---------------
1555 dnl Check if the compiler supports useful warning options.  There's a few that
1556 dnl we don't use, simply because they're too noisy:
1557 dnl
1558 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1559 dnl     -Winline (usually not worthwhile)
1560 dnl     -Wredundant-decls (system headers make this too noisy)
1561 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1562 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1563 dnl             is enabled for ncurses using "--enable-const".
1564 dnl     -pedantic
1565 dnl
1566 dnl Parameter:
1567 dnl     $1 is an optional list of gcc warning flags that a particular
1568 dnl             application might want to use, e.g., "no-unused" for
1569 dnl             -Wno-unused
1570 dnl Special:
1571 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1572 dnl
1573 AC_DEFUN([CF_GCC_WARNINGS],
1574 [
1575 AC_REQUIRE([CF_GCC_VERSION])
1576 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
1577 cat > "conftest.$ac_ext" <<EOF
1578 #line __oline__ "${as_me:-configure}"
1579 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1580 EOF
1581 if test "$INTEL_COMPILER" = yes
1582 then
1583 # The "-wdXXX" options suppress warnings:
1584 # remark #1419: external declaration in primary source file
1585 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1586 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1587 # remark #193: zero used for undefined preprocessing identifier
1588 # remark #593: variable "curs_sb_left_arrow" was set but never used
1589 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1590 # remark #869: parameter "tw" was never referenced
1591 # remark #981: operands are evaluated in unspecified order
1592 # warning #279: controlling expression is constant
1593
1594         AC_CHECKING([for $CC warning options])
1595         cf_save_CFLAGS="$CFLAGS"
1596         EXTRA_CFLAGS="$EXTRA_CFLAGS -Wall"
1597         for cf_opt in \
1598                 wd1419 \
1599                 wd1683 \
1600                 wd1684 \
1601                 wd193 \
1602                 wd593 \
1603                 wd279 \
1604                 wd810 \
1605                 wd869 \
1606                 wd981
1607         do
1608                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1609                 if AC_TRY_EVAL(ac_compile); then
1610                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1611                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1612                 fi
1613         done
1614         CFLAGS="$cf_save_CFLAGS"
1615 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
1616 then
1617         AC_CHECKING([for $CC warning options])
1618         cf_save_CFLAGS="$CFLAGS"
1619         cf_warn_CONST=""
1620         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1621         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1622         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1623         for cf_opt in W Wall \
1624                 Wbad-function-cast \
1625                 Wcast-align \
1626                 Wcast-qual \
1627                 Wdeclaration-after-statement \
1628                 Wextra \
1629                 Winline \
1630                 Wmissing-declarations \
1631                 Wmissing-prototypes \
1632                 Wnested-externs \
1633                 Wpointer-arith \
1634                 Wshadow \
1635                 Wstrict-prototypes \
1636                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
1637         do
1638                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1639                 if AC_TRY_EVAL(ac_compile); then
1640                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1641                         case "$cf_opt" in
1642                         (Winline)
1643                                 case "$GCC_VERSION" in
1644                                 ([[34]].*)
1645                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1646                                         continue;;
1647                                 esac
1648                                 ;;
1649                         (Wpointer-arith)
1650                                 case "$GCC_VERSION" in
1651                                 ([[12]].*)
1652                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1653                                         continue;;
1654                                 esac
1655                                 ;;
1656                         esac
1657                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1658                 fi
1659         done
1660         CFLAGS="$cf_save_CFLAGS"
1661 fi
1662 rm -rf ./conftest*
1663
1664 AC_SUBST(EXTRA_CFLAGS)
1665 ])dnl
1666 dnl ---------------------------------------------------------------------------
1667 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
1668 dnl -----------------
1669 AC_DEFUN([CF_GNATPREP_OPT_T],[
1670 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
1671 cf_cv_gnatprep_opt_t=no
1672 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
1673 ])
1674 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
1675 AC_SUBST(GNATPREP_OPTS)
1676 ])dnl
1677 dnl ---------------------------------------------------------------------------
1678 dnl CF_GNAT_GENERICS version: 7 updated: 2021/01/01 13:31:04
1679 dnl ----------------
1680 AC_DEFUN([CF_GNAT_GENERICS],
1681 [
1682 AC_REQUIRE([CF_GNAT_VERSION])
1683
1684 AC_MSG_CHECKING(if GNAT supports generics)
1685 case "$cf_cv_gnat_version" in
1686 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
1687         cf_gnat_generics=yes
1688         ;;
1689 (*)
1690         cf_gnat_generics=no
1691         ;;
1692 esac
1693 AC_MSG_RESULT($cf_gnat_generics)
1694
1695 if test "$cf_gnat_generics" = yes
1696 then
1697         cf_compile_generics=generics
1698         cf_generic_objects="\${GENOBJS}"
1699 else
1700         cf_compile_generics=
1701         cf_generic_objects=
1702 fi
1703
1704 AC_SUBST(cf_compile_generics)
1705 AC_SUBST(cf_generic_objects)
1706 ])dnl
1707 dnl ---------------------------------------------------------------------------
1708 dnl CF_GNAT_PROJECTS version: 13 updated: 2021/01/02 17:09:14
1709 dnl ----------------
1710 dnl GNAT projects are configured with ".gpr" project files.
1711 dnl GNAT libraries are a further development, using the project feature.
1712 AC_DEFUN([CF_GNAT_PROJECTS],
1713 [
1714 AC_REQUIRE([CF_GNAT_VERSION])
1715 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
1716
1717 cf_gnat_libraries=no
1718 cf_gnat_projects=no
1719
1720 if test "$enable_gnat_projects" != no ; then
1721 AC_MSG_CHECKING(if GNAT supports project files)
1722 case "$cf_cv_gnat_version" in
1723 (3.[[0-9]]*)
1724         ;;
1725 (*)
1726         case "$cf_cv_system_name" in
1727         (cygwin*|msys*)
1728                 ;;
1729         (*)
1730                 rm -rf ./conftest* ./*~conftest*
1731                 if mkdir conftest.src conftest.bin conftest.lib
1732                 then
1733                         cd conftest.src
1734                         rm -rf ./conftest* ./*~conftest*
1735                         cat >>library.gpr <<CF_EOF
1736 project Library is
1737   Kind := External ("LIB_KIND");
1738   for Library_Name use "ConfTest";
1739   for Object_Dir use ".";
1740   for Library_ALI_Dir use External("LIBRARY_DIR");
1741   for Library_Version use External ("SONAME");
1742   for Library_Kind use Kind;
1743   for Library_Dir use External("BUILD_DIR");
1744   Source_Dir := External ("SOURCE_DIR");
1745   for Source_Dirs use (Source_Dir);
1746 end Library;
1747 CF_EOF
1748                         cat >>confpackage.ads <<CF_EOF
1749 package ConfPackage is
1750    procedure conftest;
1751 end ConfPackage;
1752 CF_EOF
1753                         cat >>confpackage.adb <<CF_EOF
1754 with Text_IO;
1755 package body ConfPackage is
1756    procedure conftest is
1757    begin
1758       Text_IO.Put ("Hello World");
1759       Text_IO.New_Line;
1760    end conftest;
1761 end ConfPackage;
1762 CF_EOF
1763                         if ( "$cf_ada_make" $ADAFLAGS \
1764                                         -Plibrary.gpr \
1765                                         -XBUILD_DIR="`cd ../conftest.bin;pwd`" \
1766                                         -XLIBRARY_DIR="`cd ../conftest.lib;pwd`" \
1767                                         -XSOURCE_DIR="`pwd`" \
1768                                         -XSONAME=libConfTest.so.1 \
1769                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
1770                                 cf_gnat_projects=yes
1771                         fi
1772                         cd ..
1773                 fi
1774                 if test -f conftest.lib/confpackage.ali
1775                 then
1776                         cf_gnat_libraries=yes
1777                 fi
1778                 rm -rf ./conftest* ./*~conftest*
1779                 ;;
1780         esac
1781         ;;
1782 esac
1783 AC_MSG_RESULT($cf_gnat_projects)
1784 fi # enable_gnat_projects
1785
1786 if test "$cf_gnat_projects" = yes
1787 then
1788         AC_MSG_CHECKING(if GNAT supports libraries)
1789         AC_MSG_RESULT($cf_gnat_libraries)
1790 fi
1791
1792 USE_OLD_MAKERULES=""
1793 USE_GNAT_PROJECTS="#"
1794 USE_GNAT_MAKE_GPR="#"
1795 USE_GNAT_GPRBUILD="#"
1796
1797 if test "$cf_gnat_projects" = yes
1798 then
1799         USE_OLD_MAKERULES="#"
1800         USE_GNAT_PROJECTS=""
1801         if test "$cf_cv_VERSION_GPRBUILD" != no
1802         then
1803                 USE_GNAT_GPRBUILD=""
1804         elif test "$cf_cv_VERSION_GNATMAKE" != no
1805         then
1806                 USE_GNAT_MAKE_GPR=""
1807         else
1808                 AC_MSG_WARN(use old makefile rules since tools are missing)
1809         fi
1810 fi
1811
1812 if test "$cf_gnat_libraries" = yes
1813 then
1814         USE_GNAT_LIBRARIES=""
1815 else
1816         USE_GNAT_LIBRARIES="#"
1817 fi
1818
1819 AC_SUBST(USE_OLD_MAKERULES)
1820 AC_SUBST(USE_GNAT_PROJECTS)
1821 AC_SUBST(USE_GNAT_LIBRARIES)
1822 AC_SUBST(USE_GNAT_MAKE_GPR)
1823 AC_SUBST(USE_GNAT_GPRBUILD)
1824 ])dnl
1825 dnl ---------------------------------------------------------------------------
1826 dnl CF_GNAT_SIGINT version: 2 updated: 2021/01/01 13:31:04
1827 dnl --------------
1828 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
1829 dnl is noted that gnat may compile a tasking unit even for configurations which
1830 dnl fail at runtime.
1831 AC_DEFUN([CF_GNAT_SIGINT],[
1832 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
1833 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
1834
1835 package ConfTest is
1836
1837    pragma Warnings (Off);  --  the next pragma exists since 3.11p
1838    pragma Unreserve_All_Interrupts;
1839    pragma Warnings (On);
1840
1841    protected Process is
1842       procedure Stop;
1843       function Continue return Boolean;
1844       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
1845    private
1846       Done : Boolean := False;
1847    end Process;
1848
1849 end ConfTest;],
1850 [package body ConfTest is
1851    protected body Process is
1852       procedure Stop is
1853       begin
1854          Done := True;
1855       end Stop;
1856       function Continue return Boolean is
1857       begin
1858          return not Done;
1859       end Continue;
1860    end Process;
1861 end ConfTest;],
1862         [cf_cv_gnat_sigint=yes],
1863         [cf_cv_gnat_sigint=no])])
1864
1865 if test "$cf_cv_gnat_sigint" = yes ; then
1866         USE_GNAT_SIGINT=""
1867 else
1868         USE_GNAT_SIGINT="#"
1869 fi
1870 AC_SUBST(USE_GNAT_SIGINT)
1871 ])dnl
1872 dnl ---------------------------------------------------------------------------
1873 dnl CF_GNAT_TRY_LINK version: 4 updated: 2021/01/01 13:31:04
1874 dnl ----------------
1875 dnl Verify that a test program compiles/links with GNAT.
1876 dnl $cf_ada_make is set to the program that compiles/links
1877 dnl $ADAFLAGS may be set to the GNAT flags.
1878 dnl
1879 dnl $1 is the text of the spec
1880 dnl $2 is the text of the body
1881 dnl $3 is the shell command to execute if successful
1882 dnl $4 is the shell command to execute if not successful
1883 AC_DEFUN([CF_GNAT_TRY_LINK],
1884 [
1885 rm -rf ./conftest* ./*~conftest*
1886 cat >>conftest.ads <<CF_EOF
1887 $1
1888 CF_EOF
1889 cat >>conftest.adb <<CF_EOF
1890 $2
1891 CF_EOF
1892 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1893 ifelse($3,,      :,[      $3])
1894 ifelse($4,,,[else
1895    $4])
1896 fi
1897 rm -rf ./conftest* ./*~conftest*
1898 ])dnl
1899 dnl ---------------------------------------------------------------------------
1900 dnl CF_GNAT_TRY_RUN version: 6 updated: 2021/01/01 13:31:04
1901 dnl ---------------
1902 dnl Verify that a test program compiles and runs with GNAT
1903 dnl $cf_ada_make is set to the program that compiles/links
1904 dnl $ADAFLAGS may be set to the GNAT flags.
1905 dnl
1906 dnl $1 is the text of the spec
1907 dnl $2 is the text of the body
1908 dnl $3 is the shell command to execute if successful
1909 dnl $4 is the shell command to execute if not successful
1910 AC_DEFUN([CF_GNAT_TRY_RUN],
1911 [
1912 rm -rf ./conftest* ./*~conftest*
1913 cat >>conftest.ads <<CF_EOF
1914 $1
1915 CF_EOF
1916 cat >>conftest.adb <<CF_EOF
1917 $2
1918 CF_EOF
1919 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1920    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1921 ifelse($3,,      :,[      $3])
1922 ifelse($4,,,[   else
1923       $4])
1924    fi
1925 ifelse($4,,,[else
1926    $4])
1927 fi
1928 rm -rf ./conftest* ./*~conftest*
1929 ])dnl
1930 dnl ---------------------------------------------------------------------------
1931 dnl CF_GNAT_VERSION version: 22 updated: 2019/12/31 08:53:54
1932 dnl ---------------
1933 dnl $1 = cache variable to update
1934 dnl $2 = program name
1935 dnl Verify version of GNAT or related tool
1936 AC_DEFUN([CF_GNAT_VERSION],
1937 [
1938 AC_CACHE_CHECK(for ifelse($2,,gnat,$2) version, cf_cv_gnat_version,[
1939 cf_cv_gnat_version=`ifelse($2,,${cf_ada_make:-gnatmake},$2) --version 2>&1 | \
1940         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1941         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1942 ])
1943 test -z "$cf_cv_gnat_version" && cf_cv_gnat_version=no
1944 ifelse($1,,,[eval $1=$cf_cv_gnat_version; unset cf_cv_gnat_version])
1945 ])dnl
1946 dnl ---------------------------------------------------------------------------
1947 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
1948 dnl -------------
1949 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1950 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1951 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1952 dnl since it is interwoven with GNU extensions.
1953 dnl
1954 dnl Well, yes we could work around it...
1955 dnl
1956 dnl Parameters:
1957 dnl     $1 is the nominal value for _XOPEN_SOURCE
1958 AC_DEFUN([CF_GNU_SOURCE],
1959 [
1960 cf_gnu_xopen_source=ifelse($1,,500,$1)
1961
1962 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
1963 AC_TRY_COMPILE([#include <sys/types.h>],[
1964         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
1965                 return 0;
1966         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
1967                 return 0;
1968         #else
1969         #       error not GNU C library
1970         #endif],
1971         [cf_cv_gnu_library=yes],
1972         [cf_cv_gnu_library=no])
1973 ])
1974
1975 if test x$cf_cv_gnu_library = xyes; then
1976
1977         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
1978         # was changed to help a little.  newlib incorporated the change about 4
1979         # years later.
1980         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
1981                 cf_save="$CPPFLAGS"
1982                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
1983                 AC_TRY_COMPILE([#include <sys/types.h>],[
1984                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
1985                                 return 0;
1986                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
1987                                 return 0;
1988                         #else
1989                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
1990                         #endif],
1991                         [cf_cv_gnu_library_219=yes],
1992                         [cf_cv_gnu_library_219=no])
1993                 CPPFLAGS="$cf_save"
1994         ])
1995
1996         if test "x$cf_cv_gnu_library_219" = xyes; then
1997                 cf_save="$CPPFLAGS"
1998                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
1999                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
2000                         AC_TRY_COMPILE([
2001                                 #include <limits.h>
2002                                 #include <sys/types.h>
2003                                 ],[
2004                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
2005                                         return 0;
2006                                 #else
2007                                 #       error GNU C library is too old
2008                                 #endif],
2009                                 [cf_cv_gnu_dftsrc_219=yes],
2010                                 [cf_cv_gnu_dftsrc_219=no])
2011                         ])
2012                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
2013         else
2014                 cf_cv_gnu_dftsrc_219=maybe
2015         fi
2016
2017         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
2018
2019                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2020                 AC_TRY_COMPILE([#include <sys/types.h>],[
2021                         #ifndef _XOPEN_SOURCE
2022                         #error  expected _XOPEN_SOURCE to be defined
2023                         #endif],
2024                         [cf_cv_gnu_source=no],
2025                         [cf_save="$CPPFLAGS"
2026                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
2027                          AC_TRY_COMPILE([#include <sys/types.h>],[
2028                                 #ifdef _XOPEN_SOURCE
2029                                 #error  expected _XOPEN_SOURCE to be undefined
2030                                 #endif],
2031                                 [cf_cv_gnu_source=no],
2032                                 [cf_cv_gnu_source=yes])
2033                         CPPFLAGS="$cf_save"
2034                         ])
2035                 ])
2036
2037                 if test "$cf_cv_gnu_source" = yes
2038                 then
2039                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
2040                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
2041                         AC_TRY_COMPILE([#include <sys/types.h>],[
2042                                 #ifdef _DEFAULT_SOURCE
2043                                 #error  expected _DEFAULT_SOURCE to be undefined
2044                                 #endif],
2045                                 [cf_cv_default_source=no],
2046                                 [cf_cv_default_source=yes])
2047                         ])
2048                         if test "$cf_cv_default_source" = yes
2049                         then
2050                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
2051                         fi
2052                 fi
2053         fi
2054
2055 fi
2056 ])dnl
2057 dnl ---------------------------------------------------------------------------
2058 dnl CF_HEADER_PATH version: 15 updated: 2021/01/01 13:31:04
2059 dnl --------------
2060 dnl Construct a search-list of directories for a nonstandard header-file
2061 dnl
2062 dnl Parameters
2063 dnl     $1 = the variable to return as result
2064 dnl     $2 = the package name
2065 AC_DEFUN([CF_HEADER_PATH],
2066 [
2067 $1=
2068
2069 # collect the current set of include-directories from compiler flags
2070 cf_header_path_list=""
2071 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2072         for cf_header_path in $CPPFLAGS $CFLAGS
2073         do
2074                 case "$cf_header_path" in
2075                 (-I*)
2076                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2077                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2078                         cf_header_path_list="$cf_header_path_list [$]$1"
2079                         ;;
2080                 esac
2081         done
2082 fi
2083
2084 # add the variations for the package we are looking for
2085 CF_SUBDIR_PATH($1,$2,include)
2086
2087 test "$includedir" != NONE && \
2088 test "$includedir" != "/usr/include" && \
2089 test -d "$includedir" && {
2090         test -d "$includedir" &&    $1="[$]$1 $includedir"
2091         test -d "$includedir/$2" && $1="[$]$1 $includedir/$2"
2092 }
2093
2094 test "$oldincludedir" != NONE && \
2095 test "$oldincludedir" != "/usr/include" && \
2096 test -d "$oldincludedir" && {
2097         test -d "$oldincludedir"    && $1="[$]$1 $oldincludedir"
2098         test -d "$oldincludedir/$2" && $1="[$]$1 $oldincludedir/$2"
2099 }
2100
2101 $1="[$]$1 $cf_header_path_list"
2102 ])dnl
2103 dnl ---------------------------------------------------------------------------
2104 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
2105 dnl ---------------
2106 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2107 AC_DEFUN([CF_HELP_MESSAGE],
2108 [CF_ACVERSION_CHECK(2.53,[],[
2109 AC_DIVERT_HELP($1)])dnl
2110 ])dnl
2111 dnl ---------------------------------------------------------------------------
2112 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
2113 dnl ---------------
2114 dnl Construct the list of include-options according to whether we're building
2115 dnl in the source directory or using '--srcdir=DIR' option.
2116 AC_DEFUN([CF_INCLUDE_DIRS],
2117 [
2118 if test "$srcdir" != "."; then
2119         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
2120 fi
2121 CPPFLAGS="-I../include $CPPFLAGS"
2122 if test "$srcdir" != "."; then
2123         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
2124 fi
2125 CPPFLAGS="-I. $CPPFLAGS"
2126 AC_SUBST(CPPFLAGS)
2127 ])dnl
2128 dnl ---------------------------------------------------------------------------
2129 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
2130 dnl ---------------
2131 dnl prompt for/fill-in useful install-program options
2132 AC_DEFUN([CF_INSTALL_OPTS],
2133 [
2134 CF_INSTALL_OPT_S
2135 CF_INSTALL_OPT_P
2136 CF_INSTALL_OPT_O
2137 ])dnl
2138 dnl ---------------------------------------------------------------------------
2139 dnl CF_INSTALL_OPT_O version: 3 updated: 2020/12/31 20:19:42
2140 dnl ----------------
2141 dnl Almost all "install" programs default to the current user's ownership.
2142 dnl Almost - MINIX is an exception.
2143 AC_DEFUN([CF_INSTALL_OPT_O],
2144 [
2145 AC_MSG_CHECKING(if install needs to be told about ownership)
2146 case `$ac_config_guess` in
2147 (*minix)
2148         with_install_o=yes
2149         ;;
2150 (*)
2151         with_install_o=no
2152         ;;
2153 esac
2154
2155 AC_MSG_RESULT($with_install_o)
2156 if test "x$with_install_o" = xyes
2157 then
2158         INSTALL_OPT_O="`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`"
2159 else
2160         INSTALL_OPT_O=
2161 fi
2162
2163 AC_SUBST(INSTALL_OPT_O)
2164 ])dnl
2165 dnl ---------------------------------------------------------------------------
2166 dnl CF_INSTALL_OPT_P version: 3 updated: 2021/01/01 13:31:04
2167 dnl ----------------
2168 dnl Some install-programs accept a "-p" option to preserve file modification
2169 dnl timestamps.  That can be useful as an install option, as well as a way to
2170 dnl avoid the need for ranlib after copying a static archive.
2171 AC_DEFUN([CF_INSTALL_OPT_P],
2172 [
2173 : "${INSTALL:=install}"
2174 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
2175         rm -rf ./conftest*
2176         date >conftest.in
2177         mkdir conftest.out
2178         sleep 3
2179         if $INSTALL -p conftest.in conftest.out 2>/dev/null
2180         then
2181                 if test -f conftest.out/conftest.in
2182                 then
2183                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
2184                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
2185                         if test -s conftest.err
2186                         then
2187                                 cf_cv_install_p=no
2188                         else
2189                                 cf_cv_install_p=yes
2190                         fi
2191                 else
2192                         cf_cv_install_p=no
2193                 fi
2194         else
2195                 cf_cv_install_p=no
2196         fi
2197         rm -rf ./conftest*
2198 ])
2199 ])dnl
2200 dnl ---------------------------------------------------------------------------
2201 dnl CF_INSTALL_OPT_S version: 3 updated: 2021/01/05 19:23:48
2202 dnl ----------------
2203 dnl By default, we should strip executables which are installed, but leave the
2204 dnl ability to suppress that for unit-testing.
2205 AC_DEFUN([CF_INSTALL_OPT_S],
2206 [
2207 AC_MSG_CHECKING(if you want to install stripped executables)
2208 CF_ARG_DISABLE(stripping,
2209         [  --disable-stripping     do not strip (debug info) installed executables],
2210         [enable_stripping=no],
2211         [enable_stripping=yes])
2212 AC_MSG_RESULT($enable_stripping)
2213
2214 if test "$enable_stripping" = yes
2215 then
2216         INSTALL_OPT_S="-s"
2217 else
2218         INSTALL_OPT_S=
2219 fi
2220 AC_SUBST(INSTALL_OPT_S)
2221 ])dnl
2222 dnl ---------------------------------------------------------------------------
2223 dnl CF_INTEL_COMPILER version: 9 updated: 2023/02/18 17:41:25
2224 dnl -----------------
2225 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2226 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2227 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2228 dnl
2229 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2230 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2231 dnl the wrappers for gcc and g++ warnings.
2232 dnl
2233 dnl $1 = GCC (default) or GXX
2234 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2235 dnl $3 = CFLAGS (default) or CXXFLAGS
2236 AC_DEFUN([CF_INTEL_COMPILER],[
2237 AC_REQUIRE([AC_CANONICAL_HOST])
2238 ifelse([$2],,INTEL_COMPILER,[$2])=no
2239
2240 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2241         case "$host_os" in
2242         (linux*|gnu*)
2243                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2244                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2245                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2246                 AC_TRY_COMPILE([],[
2247 #ifdef __INTEL_COMPILER
2248 #else
2249 #error __INTEL_COMPILER is not defined
2250 #endif
2251 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2252 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
2253 ],[])
2254                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2255                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2256                 ;;
2257         esac
2258 fi
2259 ])dnl
2260 dnl ---------------------------------------------------------------------------
2261 dnl CF_LARGEFILE version: 12 updated: 2020/03/19 20:23:48
2262 dnl ------------
2263 dnl Add checks for large file support.
2264 AC_DEFUN([CF_LARGEFILE],[
2265 ifdef([AC_FUNC_FSEEKO],[
2266         AC_SYS_LARGEFILE
2267         if test "$enable_largefile" != no ; then
2268         AC_FUNC_FSEEKO
2269
2270         # Normally we would collect these definitions in the config.h,
2271         # but (like _XOPEN_SOURCE), some environments rely on having these
2272         # defined before any of the system headers are included.  Another
2273         # case comes up with C++, e.g., on AIX the compiler compiles the
2274         # header files by themselves before looking at the body files it is
2275         # told to compile.  For ncurses, those header files do not include
2276         # the config.h
2277         if test "$ac_cv_sys_large_files" != no
2278         then
2279                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
2280         fi
2281         if test "$ac_cv_sys_largefile_source" != no
2282         then
2283                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
2284         fi
2285         if test "$ac_cv_sys_file_offset_bits" != no
2286         then
2287                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
2288         fi
2289
2290         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2291                 AC_TRY_COMPILE([
2292 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
2293 #include <sys/types.h>
2294 #include <dirent.h>
2295                 ],[
2296                 /* if transitional largefile support is setup, this is true */
2297                 extern struct dirent64 * readdir(DIR *);
2298                 struct dirent64 *x = readdir((DIR *)0);
2299                 struct dirent *y = readdir((DIR *)0);
2300                 int z = x - y;
2301                 (void)z;
2302                 ],
2303                 [cf_cv_struct_dirent64=yes],
2304                 [cf_cv_struct_dirent64=no])
2305         ])
2306         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
2307         fi
2308 ])
2309 ])
2310 dnl ---------------------------------------------------------------------------
2311 dnl CF_LD_RPATH_OPT version: 9 updated: 2021/01/01 13:31:04
2312 dnl ---------------
2313 dnl For the given system and compiler, find the compiler flags to pass to the
2314 dnl loader to use the "rpath" feature.
2315 AC_DEFUN([CF_LD_RPATH_OPT],
2316 [
2317 AC_REQUIRE([CF_CHECK_CACHE])
2318
2319 LD_RPATH_OPT=
2320 if test "x$cf_cv_enable_rpath" != xno
2321 then
2322         AC_MSG_CHECKING(for an rpath option)
2323         case "$cf_cv_system_name" in
2324         (irix*)
2325                 if test "$GCC" = yes; then
2326                         LD_RPATH_OPT="-Wl,-rpath,"
2327                 else
2328                         LD_RPATH_OPT="-rpath "
2329                 fi
2330                 ;;
2331         (linux*|gnu*|k*bsd*-gnu|freebsd*)
2332                 LD_RPATH_OPT="-Wl,-rpath,"
2333                 ;;
2334         (openbsd[[2-9]].*|mirbsd*)
2335                 LD_RPATH_OPT="-Wl,-rpath,"
2336                 ;;
2337         (dragonfly*)
2338                 LD_RPATH_OPT="-rpath "
2339                 ;;
2340         (netbsd*)
2341                 LD_RPATH_OPT="-Wl,-rpath,"
2342                 ;;
2343         (osf*|mls+*)
2344                 LD_RPATH_OPT="-rpath "
2345                 ;;
2346         (solaris2*)
2347                 LD_RPATH_OPT="-R"
2348                 ;;
2349         (*)
2350                 ;;
2351         esac
2352         AC_MSG_RESULT($LD_RPATH_OPT)
2353
2354         case "x$LD_RPATH_OPT" in
2355         (x-R*)
2356                 AC_MSG_CHECKING(if we need a space after rpath option)
2357                 cf_save_LIBS="$LIBS"
2358                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
2359                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
2360                 LIBS="$cf_save_LIBS"
2361                 AC_MSG_RESULT($cf_rpath_space)
2362                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
2363                 ;;
2364         esac
2365 fi
2366 ])dnl
2367 dnl ---------------------------------------------------------------------------
2368 dnl CF_LIBRARY_PATH version: 11 updated: 2021/01/01 13:31:04
2369 dnl ---------------
2370 dnl Construct a search-list of directories for a nonstandard library-file
2371 dnl
2372 dnl Parameters
2373 dnl     $1 = the variable to return as result
2374 dnl     $2 = the package name
2375 AC_DEFUN([CF_LIBRARY_PATH],
2376 [
2377 $1=
2378 cf_library_path_list=""
2379 if test -n "${LDFLAGS}${LIBS}" ; then
2380         for cf_library_path in $LDFLAGS $LIBS
2381         do
2382                 case "$cf_library_path" in
2383                 (-L*)
2384                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
2385                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
2386                         cf_library_path_list="$cf_library_path_list [$]$1"
2387                         ;;
2388                 esac
2389         done
2390 fi
2391
2392 CF_SUBDIR_PATH($1,$2,lib)
2393
2394 $1="$cf_library_path_list [$]$1"
2395 ])dnl
2396 dnl ---------------------------------------------------------------------------
2397 dnl CF_LIB_PREFIX version: 14 updated: 2021/01/01 13:31:04
2398 dnl -------------
2399 dnl Compute the library-prefix for the given host system
2400 dnl $1 = variable to set
2401 define([CF_LIB_PREFIX],
2402 [
2403         case "$cf_cv_system_name" in
2404         (OS/2*|os2*)
2405                 if test "$DFT_LWR_MODEL" = libtool; then
2406                         LIB_PREFIX='lib'
2407                 else
2408                         LIB_PREFIX=''
2409                 fi
2410                 ;;
2411         (*-msvc*)
2412                 LIB_PREFIX=''
2413                 ;;
2414         (*)     LIB_PREFIX='lib'
2415                 ;;
2416         esac
2417 ifelse($1,,,[$1=$LIB_PREFIX])
2418         AC_SUBST(LIB_PREFIX)
2419 ])dnl
2420 dnl ---------------------------------------------------------------------------
2421 dnl CF_LIB_SUFFIX version: 28 updated: 2021/01/01 16:53:59
2422 dnl -------------
2423 dnl Compute the library file-suffix from the given model name
2424 dnl $1 = model name
2425 dnl $2 = variable to set (the nominal library suffix)
2426 dnl $3 = dependency variable to set (actual filename)
2427 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
2428 AC_DEFUN([CF_LIB_SUFFIX],
2429 [
2430         case X$1 in
2431         (Xlibtool)
2432                 $2='.la'
2433                 $3=[$]$2
2434                 ;;
2435         (Xdebug)
2436                 case "$cf_cv_system_name" in
2437                 (*-msvc*)
2438                         $2='_g.lib'
2439                         ;;
2440                 (*)
2441                         $2='_g.a'
2442                         ;;
2443                 esac
2444                 $3=[$]$2
2445                 ;;
2446         (Xprofile)
2447                 case "$cf_cv_system_name" in
2448                 (*-msvc*)
2449                         $2='_p.lib'
2450                         ;;
2451                 (*)
2452                         $2='_p.a'
2453                         ;;
2454                 esac
2455                 $3=[$]$2
2456                 ;;
2457         (Xshared)
2458                 case "$cf_cv_system_name" in
2459                 (aix[[5-7]]*)
2460                         $2='.so'
2461                         $3=[$]$2
2462                         ;;
2463                 (*-msvc*)
2464                         $2='.dll'
2465                         $3='.dll.lib'
2466                         ;;
2467                 (cygwin*|msys*|mingw*)
2468                         $2='.dll'
2469                         $3='.dll.a'
2470                         ;;
2471                 (darwin*)
2472                         $2='.dylib'
2473                         $3=[$]$2
2474                         ;;
2475                 (hpux*)
2476                         case "$target" in
2477                         (ia64*)
2478                                 $2='.so'
2479                                 $3=[$]$2
2480                                 ;;
2481                         (*)
2482                                 $2='.sl'
2483                                 $3=[$]$2
2484                                 ;;
2485                         esac
2486                         ;;
2487                 (*)
2488                         $2='.so'
2489                         $3=[$]$2
2490                         ;;
2491                 esac
2492                 ;;
2493         (*)
2494                 case "$target" in
2495                 (*-msvc*)
2496                         $2='.lib'
2497                         ;;
2498                 (*)
2499                         $2='.a'
2500                         ;;
2501                 esac
2502                 $3=[$]$2
2503                 ;;
2504         esac
2505         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
2506         then
2507                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
2508                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
2509         fi
2510 ])dnl
2511 dnl ---------------------------------------------------------------------------
2512 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
2513 dnl -----------
2514 dnl Compute the string to append to -library from the given model name
2515 dnl $1 = model name
2516 dnl $2 = variable to set
2517 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
2518 AC_DEFUN([CF_LIB_TYPE],
2519 [
2520         case $1 in
2521         (libtool) $2=''   ;;
2522         (normal)  $2=''   ;;
2523         (debug)   $2='_g' ;;
2524         (profile) $2='_p' ;;
2525         (shared)  $2=''   ;;
2526         esac
2527         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
2528 ])dnl
2529 dnl ---------------------------------------------------------------------------
2530 dnl CF_LINK_DATAONLY version: 13 updated: 2020/02/08 15:59:30
2531 dnl ----------------
2532 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
2533 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
2534 dnl have to provide wrappers for global tables to ensure they're linked
2535 dnl properly.
2536 AC_DEFUN([CF_LINK_DATAONLY],
2537 [
2538 AC_MSG_CHECKING([if data-only library module links])
2539 AC_CACHE_VAL(cf_cv_link_dataonly,[
2540         rm -f conftest.a
2541         cat >conftest.$ac_ext <<EOF
2542 #line __oline__ "configure"
2543 int     testdata[[3]] = { 123, 456, 789 };
2544 EOF
2545         if AC_TRY_EVAL(ac_compile) ; then
2546                 mv conftest.o data.o && \
2547                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
2548         fi
2549         rm -f conftest.$ac_ext data.o
2550         cat >conftest.$ac_ext <<EOF
2551 #line __oline__ "configure"
2552 int     testfunc(void)
2553 {
2554 #if defined(NeXT)
2555         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
2556 #else
2557         extern int testdata[[3]];
2558         return testdata[[0]] == 123
2559            &&  testdata[[1]] == 456
2560            &&  testdata[[2]] == 789;
2561 #endif
2562 }
2563 EOF
2564         if AC_TRY_EVAL(ac_compile); then
2565                 mv conftest.o func.o && \
2566                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
2567         fi
2568         rm -f conftest.$ac_ext func.o
2569         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
2570         cf_saveLIBS="$LIBS"
2571         LIBS="conftest.a $LIBS"
2572         AC_TRY_RUN([
2573         int main(void)
2574         {
2575                 extern int testfunc();
2576                 ${cf_cv_main_return:-return} (!testfunc());
2577         }
2578         ],
2579         [cf_cv_link_dataonly=yes],
2580         [cf_cv_link_dataonly=no],
2581         [cf_cv_link_dataonly=unknown])
2582         LIBS="$cf_saveLIBS"
2583         ])
2584 AC_MSG_RESULT($cf_cv_link_dataonly)
2585
2586 if test "$cf_cv_link_dataonly" = no ; then
2587         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
2588         BROKEN_LINKER=1
2589 fi
2590 AC_SUBST(BROKEN_LINKER)
2591
2592 ])dnl
2593 dnl ---------------------------------------------------------------------------
2594 dnl CF_MAKEFLAGS version: 21 updated: 2021/09/04 06:47:34
2595 dnl ------------
2596 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
2597 dnl options to lower-levels.  It is very useful for "make -n" -- if we have it.
2598 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
2599 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
2600 AC_DEFUN([CF_MAKEFLAGS],
2601 [AC_REQUIRE([AC_PROG_FGREP])dnl
2602
2603 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
2604         cf_cv_makeflags=''
2605         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
2606         do
2607                 cat >cf_makeflags.tmp <<CF_EOF
2608 SHELL = $SHELL
2609 all :
2610         @ echo '.$cf_option'
2611 CF_EOF
2612                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | ${FGREP-fgrep} -v "ing directory" | sed -e 's,[[  ]]*$,,'`
2613                 case "$cf_result" in
2614                 (.*k|.*kw)
2615                         cf_result="`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`"
2616                         case "$cf_result" in
2617                         (.*CC=*)        cf_cv_makeflags=
2618                                 ;;
2619                         (*)     cf_cv_makeflags=$cf_option
2620                                 ;;
2621                         esac
2622                         break
2623                         ;;
2624                 (.-)
2625                         ;;
2626                 (*)
2627                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
2628                         ;;
2629                 esac
2630         done
2631         rm -f cf_makeflags.tmp
2632 ])
2633
2634 AC_SUBST(cf_cv_makeflags)
2635 ])dnl
2636 dnl ---------------------------------------------------------------------------
2637 dnl CF_MAKE_PHONY version: 3 updated: 2021/01/08 16:08:21
2638 dnl -------------
2639 dnl Check if the make-program handles a ".PHONY" target, e.g,. a target which
2640 dnl acts as a placeholder.
2641 dnl
2642 dnl The ".PHONY" feature was proposed in 2011 here
2643 dnl     https://www.austingroupbugs.net/view.php?id=523
2644 dnl and is scheduled for release in P1003.1 Issue 8 (late 2022).
2645 dnl
2646 dnl This is not supported by SVr4 make (or SunOS 4, 4.3SD, etc), but works with
2647 dnl a few others (i.e., GNU make and the non-POSIX "BSD" make):
2648 dnl
2649 dnl + This is a GNU make feature (since April 1988, but in turn from binutils,
2650 dnl   date unspecified).
2651 dnl
2652 dnl + It was adopted in NetBSD make in June 1995.
2653 dnl
2654 dnl + The other BSD make programs are derived from the NetBSD make (and for
2655 dnl   that reason are not actually different "implementations").
2656 dnl
2657 dnl + Some features of NetBSD make were actually adapted from pmake, which
2658 dnl   began as a modified GNU make starting in 1993.
2659 dnl
2660 dnl + Version 3.8 of the dmake program in January 1992 also implemented this
2661 dnl   GNU make extension, but is less well known than the BSD make.
2662 AC_DEFUN([CF_MAKE_PHONY],[
2663 AC_CACHE_CHECK(for \".PHONY\" make-support, cf_cv_make_PHONY,[
2664         rm -rf conftest*
2665         (
2666                 mkdir conftest || exit 1
2667                 cd conftest
2668                 cat >makefile <<'CF_EOF'
2669 .PHONY: always
2670 DATA=0
2671 always: always.out
2672         @echo "** making [$]@ [$](DATA)"
2673 once: once.out
2674         @echo "** making [$]@ [$](DATA)"
2675 always.out:
2676         @echo "** making [$]@ [$](DATA)"
2677         echo [$](DATA) > [$]@
2678 once.out:
2679         @echo "** making [$]@ [$](DATA)"
2680         echo [$](DATA) > [$]@
2681 CF_EOF
2682                 for cf_data in 1 2 3
2683                 do
2684                         ${MAKE:-make} always DATA=$cf_data
2685                         ${MAKE:-make} once   DATA=$cf_data
2686                         ${MAKE:-make} -t always once
2687                         if test -f always ; then
2688                                 echo "no (case 1)" > ../conftest.tmp
2689                         elif test ! -f always.out ; then
2690                                 echo "no (case 2)" > ../conftest.tmp
2691                         elif test ! -f once.out ; then
2692                                 echo "no (case 3)" > ../conftest.tmp
2693                         elif ! cmp -s always.out once.out ; then
2694                                 echo "no (case 4)" > ../conftest.tmp
2695                                 diff always.out once.out
2696                         else
2697                                 cf_check="`cat always.out`"
2698                                 if test "x$cf_check" != "x$cf_data" ; then
2699                                         echo "no (case 5)" > ../conftest.tmp
2700                                 else
2701                                         echo yes > ../conftest.tmp
2702                                         rm -f ./*.out
2703                                         continue
2704                                 fi
2705                         fi
2706                         break
2707                 done
2708         ) >&AC_FD_CC 2>&1
2709         cf_cv_make_PHONY="`cat conftest.tmp`"
2710         rm -rf conftest*
2711 ])
2712 MAKE_NO_PHONY="#"
2713 MAKE_PHONY="#"
2714 test "x$cf_cv_make_PHONY" = xyes && MAKE_PHONY=
2715 test "x$cf_cv_make_PHONY" != xyes && MAKE_NO_PHONY=
2716 AC_SUBST(MAKE_NO_PHONY)
2717 AC_SUBST(MAKE_PHONY)
2718 ])dnl
2719 dnl ---------------------------------------------------------------------------
2720 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
2721 dnl ------------
2722 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
2723 dnl a monocase filesystem.
2724 AC_DEFUN([CF_MAKE_TAGS],[
2725 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
2726
2727 AC_CHECK_PROGS(CTAGS, exctags ctags)
2728 AC_CHECK_PROGS(ETAGS, exetags etags)
2729
2730 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
2731
2732 if test "$cf_cv_mixedcase" = yes ; then
2733         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
2734 else
2735         MAKE_UPPER_TAGS=no
2736 fi
2737
2738 if test "$MAKE_UPPER_TAGS" = yes ; then
2739         MAKE_UPPER_TAGS=
2740 else
2741         MAKE_UPPER_TAGS="#"
2742 fi
2743
2744 if test "$MAKE_LOWER_TAGS" = yes ; then
2745         MAKE_LOWER_TAGS=
2746 else
2747         MAKE_LOWER_TAGS="#"
2748 fi
2749
2750 AC_SUBST(CTAGS)
2751 AC_SUBST(ETAGS)
2752
2753 AC_SUBST(MAKE_UPPER_TAGS)
2754 AC_SUBST(MAKE_LOWER_TAGS)
2755 ])dnl
2756 dnl ---------------------------------------------------------------------------
2757 dnl CF_MIXEDCASE_FILENAMES version: 9 updated: 2021/01/01 16:53:59
2758 dnl ----------------------
2759 dnl Check if the file-system supports mixed-case filenames.  If we're able to
2760 dnl create a lowercase name and see it as uppercase, it doesn't support that.
2761 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
2762 [
2763 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2764 if test "$cross_compiling" = yes ; then
2765         case "$target_alias" in
2766         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*|darwin*)
2767                 cf_cv_mixedcase=no
2768                 ;;
2769         (*)
2770                 cf_cv_mixedcase=yes
2771                 ;;
2772         esac
2773 else
2774         rm -f conftest CONFTEST
2775         echo test >conftest
2776         if test -f CONFTEST ; then
2777                 cf_cv_mixedcase=no
2778         else
2779                 cf_cv_mixedcase=yes
2780         fi
2781         rm -f conftest CONFTEST
2782 fi
2783 ])
2784 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2785 ])dnl
2786 dnl ---------------------------------------------------------------------------
2787 dnl CF_MKSTEMP version: 12 updated: 2023/01/05 17:53:11
2788 dnl ----------
2789 dnl Check for a working mkstemp.  This creates two files, checks that they are
2790 dnl successfully created and distinct (AmigaOS apparently fails on the last).
2791 AC_DEFUN([CF_MKSTEMP],[
2792 AC_CHECK_HEADERS( \
2793 unistd.h \
2794 )
2795 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
2796 rm -rf ./conftest*
2797 AC_TRY_RUN([
2798 $ac_includes_default
2799
2800 int main(void)
2801 {
2802         char *tmpl = "conftestXXXXXX";
2803         char name[2][80];
2804         int n;
2805         int result = 0;
2806         int fd;
2807         struct stat sb;
2808
2809         umask(077);
2810         for (n = 0; n < 2; ++n) {
2811                 strcpy(name[n], tmpl);
2812                 if ((fd = mkstemp(name[n])) >= 0) {
2813                         if (!strcmp(name[n], tmpl)
2814                          || stat(name[n], &sb) != 0
2815                          || (sb.st_mode & S_IFMT) != S_IFREG
2816                          || (sb.st_mode & 077) != 0) {
2817                                 result = 1;
2818                         }
2819                         close(fd);
2820                 }
2821         }
2822         if (result == 0
2823          && !strcmp(name[0], name[1]))
2824                 result = 1;
2825         ${cf_cv_main_return:-return}(result);
2826 }
2827 ],[cf_cv_func_mkstemp=yes
2828 ],[cf_cv_func_mkstemp=no
2829 ],[cf_cv_func_mkstemp=maybe])
2830 ])
2831 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
2832         AC_CHECK_FUNC(mkstemp)
2833 fi
2834 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
2835         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
2836 fi
2837 ])dnl
2838 dnl ---------------------------------------------------------------------------
2839 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2840 dnl ----------
2841 dnl Write a debug message to config.log, along with the line number in the
2842 dnl configure script.
2843 AC_DEFUN([CF_MSG_LOG],[
2844 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2845 ])dnl
2846 dnl ---------------------------------------------------------------------------
2847 dnl CF_NCURSES_ADDON version: 6 updated: 2021/01/04 19:33:05
2848 dnl ----------------
2849 dnl Configure an ncurses add-on, built outside the ncurses tree.
2850 AC_DEFUN([CF_NCURSES_ADDON],[
2851 AC_REQUIRE([CF_NCURSES_CONFIG])
2852
2853 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
2854
2855 AC_MSG_CHECKING(if you want wide-character code)
2856 AC_ARG_ENABLE(widec,
2857         [  --enable-widec          compile with wide-char/UTF-8 code],
2858         [with_widec=$enableval],
2859         [with_widec=no])
2860 AC_MSG_RESULT($with_widec)
2861 if test "$with_widec" = yes ; then
2862         CF_UTF8_LIB
2863         CF_NCURSES_CONFIG(ncursesw)
2864 else
2865         CF_NCURSES_CONFIG(ncurses)
2866 fi
2867
2868 if test "$NCURSES_CONFIG_PKG" != none ; then
2869         cf_version=`$PKG_CONFIG --modversion $NCURSES_CONFIG_PKG 2>/dev/null`
2870
2871         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2872         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2873         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2874
2875         cf_cv_abi_version=`$PKG_CONFIG --variable=abi_version $NCURSES_CONFIG_PKG 2>/dev/null`
2876         if test -z "$cf_cv_abi_version"
2877         then
2878                 cf_cv_abi_version=`$PKG_CONFIG --variable=major_version $NCURSES_CONFIG_PKG 2>/dev/null`
2879         fi
2880
2881 elif test "$NCURSES_CONFIG" != none ; then
2882
2883         cf_version=`$NCURSES_CONFIG --version 2>/dev/null`
2884
2885         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2886         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2887         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2888
2889         # ABI version is not available from headers
2890         cf_cv_abi_version=`$NCURSES_CONFIG --abi-version 2>/dev/null`
2891
2892 else
2893
2894         for cf_name in MAJOR MINOR PATCH
2895         do
2896         cat >conftest.$ac_ext <<CF_EOF
2897         #include <${cf_cv_ncurses_header:-curses.h}>
2898         AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
2899 CF_EOF
2900                 cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
2901                 AC_TRY_EVAL(cf_try)
2902                 if test -f conftest.out ; then
2903                         cf_result=`sed -e "s/^.*AUTOCONF_${cf_name}[[   ]][[    ]]*//" conftest.out`
2904                         eval NCURSES_$cf_name=\"$cf_result\"
2905                         # cat conftest.$ac_ext
2906                         # cat conftest.out
2907                 fi
2908         done
2909
2910         cf_cv_abi_version=${NCURSES_MAJOR}
2911
2912 fi
2913
2914 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
2915
2916 dnl Show the computed version, for logging
2917 cf_cv_timestamp=`date`
2918
2919 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
2920
2921 dnl We need these values in the generated headers
2922 AC_SUBST(NCURSES_MAJOR)
2923 AC_SUBST(NCURSES_MINOR)
2924 AC_SUBST(NCURSES_PATCH)
2925
2926 dnl We need these values in the generated makefiles
2927 AC_SUBST(cf_cv_rel_version)
2928 AC_SUBST(cf_cv_abi_version)
2929
2930 dnl FIXME - not needed for Ada95
2931 AC_SUBST(cf_cv_builtin_bool)
2932 AC_SUBST(cf_cv_header_stdbool_h)
2933 AC_SUBST(cf_cv_type_of_bool)dnl
2934
2935 ])
2936 dnl ---------------------------------------------------------------------------
2937 dnl CF_NCURSES_CC_CHECK version: 6 updated: 2023/02/18 17:47:58
2938 dnl -------------------
2939 dnl Check if we can compile with ncurses' header file
2940 dnl $1 is the cache variable to set
2941 dnl $2 is the header-file to include
2942 dnl $3 is the root name (ncurses or ncursesw)
2943 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2944         AC_TRY_COMPILE([
2945 ]ifelse($3,ncursesw,[
2946 #define _XOPEN_SOURCE_EXTENDED
2947 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2948 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2949 ])[
2950 #include <$2>],[
2951 #ifdef NCURSES_VERSION
2952 ]ifelse($3,ncursesw,[
2953 #ifndef WACS_BSSB
2954         #error WACS_BSSB is not defined
2955 #endif
2956 ])[
2957 printf("%s\\n", NCURSES_VERSION);
2958 #else
2959 #ifdef __NCURSES_H
2960 printf("old\\n");
2961 #else
2962         #error __NCURSES_H is not defined
2963 #endif
2964 #endif
2965         ]
2966         ,[$1=$2]
2967         ,[$1=no])
2968 ])dnl
2969 dnl ---------------------------------------------------------------------------
2970 dnl CF_NCURSES_CONFIG version: 28 updated: 2021/08/28 15:20:37
2971 dnl -----------------
2972 dnl Tie together the configure-script macros for ncurses, preferring these in
2973 dnl order:
2974 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2975 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2976 dnl c) just plain libraries
2977 dnl
2978 dnl $1 is the root library name (default: "ncurses")
2979 AC_DEFUN([CF_NCURSES_CONFIG],[
2980 AC_REQUIRE([CF_PKG_CONFIG])
2981 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2982 cf_have_ncuconfig=no
2983
2984 if test "x${PKG_CONFIG:=none}" != xnone; then
2985         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2986         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2987                 AC_MSG_RESULT(yes)
2988
2989                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2990                 cf_have_ncuconfig=unknown
2991
2992                 cf_save_CFLAGS="$CFLAGS"
2993                 cf_save_CPPFLAGS="$CPPFLAGS"
2994                 cf_save_LIBS="$LIBS"
2995
2996                 cf_pkg_cflags="`$PKG_CONFIG --cflags $cf_ncuconfig_root`"
2997                 cf_pkg_libs="`$PKG_CONFIG --libs $cf_ncuconfig_root`"
2998
2999                 # while -W for passing linker flags is prevalent, it is not "standard".
3000                 # At least one wrapper for c89/c99 (in Apple's xcode) has its own
3001                 # incompatible _and_ non-standard -W option which gives an error.  Work
3002                 # around that pitfall.
3003                 case "x${CC}@@${cf_pkg_libs}@${cf_pkg_cflags}" in
3004                 (x*c[[89]]9@@*-W*)
3005                         CF_ADD_CFLAGS($cf_pkg_cflags)
3006                         CF_ADD_LIBS($cf_pkg_libs)
3007
3008                         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
3009                                 [initscr(); mousemask(0,0); tigetstr((char *)0);],
3010                                 [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
3011                                         int main(void)
3012                                         { const char *xx = curses_version(); return (xx == 0); }],
3013                                         [cf_test_ncuconfig=yes],
3014                                         [cf_test_ncuconfig=no],
3015                                         [cf_test_ncuconfig=maybe])],
3016                                 [cf_test_ncuconfig=no])
3017
3018                         CFLAGS="$cf_save_CFLAGS"
3019                         CPPFLAGS="$cf_save_CPPFLAGS"
3020                         LIBS="$cf_save_LIBS"
3021
3022                         if test "x$cf_test_ncuconfig" != xyes; then
3023                                 cf_temp=`echo "x$cf_pkg_cflags" | sed -e s/^x// -e 's/-W[[^     ]]*//g'`
3024                                 cf_pkg_cflags="$cf_temp"
3025                                 cf_temp=`echo "x$cf_pkg_libs" | sed -e s/^x// -e 's/-W[[^       ]]*//g'`
3026                                 cf_pkg_libs="$cf_temp"
3027                         fi
3028                         ;;
3029                 esac
3030
3031                 CF_APPEND_CFLAGS($cf_pkg_cflags)
3032                 CF_ADD_LIBS($cf_pkg_libs)
3033
3034                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
3035                         [initscr(); mousemask(0,0); tigetstr((char *)0);],
3036                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
3037                                 int main(void)
3038                                 { const char *xx = curses_version(); return (xx == 0); }],
3039                                 [cf_have_ncuconfig=yes],
3040                                 [cf_have_ncuconfig=no],
3041                                 [cf_have_ncuconfig=maybe])],
3042                         [cf_have_ncuconfig=no])
3043                 AC_MSG_RESULT($cf_have_ncuconfig)
3044                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
3045                 if test "$cf_have_ncuconfig" != "yes"
3046                 then
3047                         CPPFLAGS="$cf_save_CPPFLAGS"
3048                         LIBS="$cf_save_LIBS"
3049                         NCURSES_CONFIG_PKG=none
3050                 else
3051                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
3052                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
3053                         CF_TERM_HEADER
3054                 fi
3055
3056         else
3057                 AC_MSG_RESULT(no)
3058                 NCURSES_CONFIG_PKG=none
3059         fi
3060 else
3061         NCURSES_CONFIG_PKG=none
3062 fi
3063
3064 if test "x$cf_have_ncuconfig" = "xno"; then
3065         cf_ncurses_config="${cf_ncuconfig_root}${NCURSES_CONFIG_SUFFIX}-config"; echo "Looking for ${cf_ncurses_config}"
3066
3067         CF_ACVERSION_CHECK(2.52,
3068                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
3069                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
3070
3071         if test "$NCURSES_CONFIG" != none ; then
3072
3073                 CF_APPEND_CFLAGS(`$NCURSES_CONFIG --cflags`)
3074                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
3075
3076                 # even with config script, some packages use no-override for curses.h
3077                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
3078
3079                 dnl like CF_NCURSES_CPPFLAGS
3080                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
3081
3082                 dnl like CF_NCURSES_LIBS
3083                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
3084                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
3085
3086                 dnl like CF_NCURSES_VERSION
3087                 cf_cv_ncurses_version="`$NCURSES_CONFIG --version`"
3088
3089         else
3090
3091                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
3092                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
3093
3094         fi
3095 else
3096         NCURSES_CONFIG=none
3097 fi
3098 ])dnl
3099 dnl ---------------------------------------------------------------------------
3100 dnl CF_NCURSES_CPPFLAGS version: 22 updated: 2021/01/02 09:31:20
3101 dnl -------------------
3102 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
3103 dnl the CPPFLAGS variable so we can include its header.
3104 dnl
3105 dnl The header files may be installed as either curses.h, or ncurses.h (would
3106 dnl be obsolete, except that some packagers prefer this name to distinguish it
3107 dnl from a "native" curses implementation).  If not installed for overwrite,
3108 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
3109 dnl /usr/include/ncurses), but someone may have installed overwriting the
3110 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
3111 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
3112 dnl the header.
3113 dnl
3114 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
3115 dnl is already in the include-path, don't even bother with this, since we cannot
3116 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
3117 dnl
3118 dnl The optional parameter gives the root name of the library, in case it is
3119 dnl not installed as the default curses library.  That is how the
3120 dnl wide-character version of ncurses is installed.
3121 AC_DEFUN([CF_NCURSES_CPPFLAGS],
3122 [AC_REQUIRE([CF_WITH_CURSES_DIR])
3123
3124 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
3125 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
3126
3127 test -n "$cf_cv_curses_dir" && \
3128 test "$cf_cv_curses_dir" != "no" && { \
3129   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
3130 }
3131
3132 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
3133         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
3134         { test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw; } && cf_header_list="$cf_header_list curses.h ncurses.h"
3135         for cf_header in $cf_header_list
3136         do
3137                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
3138                 test "$cf_cv_ncurses_h" != no && break
3139         done
3140 ])
3141
3142 CF_NCURSES_HEADER
3143 CF_TERM_HEADER
3144
3145 # some applications need this, but should check for NCURSES_VERSION
3146 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
3147
3148 CF_NCURSES_VERSION
3149 ])dnl
3150 dnl ---------------------------------------------------------------------------
3151 dnl CF_NCURSES_HEADER version: 7 updated: 2021/01/04 19:33:05
3152 dnl -----------------
3153 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
3154 dnl variations of ncurses' installs.
3155 dnl
3156 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
3157 AC_DEFUN([CF_NCURSES_HEADER],[
3158
3159 if test "$cf_cv_ncurses_h" != no ; then
3160         cf_cv_ncurses_header=$cf_cv_ncurses_h
3161 else
3162
3163 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
3164         test -n "$verbose" && echo
3165         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
3166         test -n "$verbose" && echo "search path $cf_search"
3167         cf_save2_CPPFLAGS="$CPPFLAGS"
3168         for cf_incdir in $cf_search
3169         do
3170                 CF_ADD_INCDIR($cf_incdir)
3171                 for cf_header in \
3172                         ncurses.h \
3173                         curses.h
3174                 do
3175                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
3176                         if test "$cf_cv_ncurses_h2" != no ; then
3177                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
3178                                 test -n "$verbose" && echo $ECHO_N "    ... found $ECHO_C" 1>&AC_FD_MSG
3179                                 break
3180                         fi
3181                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
3182                 done
3183                 CPPFLAGS="$cf_save2_CPPFLAGS"
3184                 test "$cf_cv_ncurses_h2" != no && break
3185         done
3186         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
3187         ])
3188
3189         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
3190         cf_cv_ncurses_header="`basename "$cf_cv_ncurses_h2"`"
3191         if test "`basename "$cf_1st_incdir"`" = "$cf_ncuhdr_root" ; then
3192                 cf_cv_ncurses_header="$cf_ncuhdr_root/$cf_cv_ncurses_header"
3193         fi
3194         CF_ADD_INCDIR($cf_1st_incdir)
3195
3196 fi
3197
3198 # Set definitions to allow ifdef'ing for ncurses.h
3199
3200 case "$cf_cv_ncurses_header" in
3201 (*ncurses.h)
3202         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
3203         ;;
3204 esac
3205
3206 case "$cf_cv_ncurses_header" in
3207 (ncurses/curses.h|ncurses/ncurses.h)
3208         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
3209         ;;
3210 (ncursesw/curses.h|ncursesw/ncurses.h)
3211         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
3212         ;;
3213 esac
3214
3215 ])dnl
3216 dnl ---------------------------------------------------------------------------
3217 dnl CF_NCURSES_LIBS version: 21 updated: 2021/09/04 06:37:12
3218 dnl ---------------
3219 dnl Look for the ncurses library.  This is a little complicated on Linux,
3220 dnl because it may be linked with the gpm (general purpose mouse) library.
3221 dnl Some distributions have gpm linked with (bsd) curses, which makes it
3222 dnl unusable with ncurses.  However, we don't want to link with gpm unless
3223 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
3224 dnl and the linker will record a dependency.
3225 dnl
3226 dnl The optional parameter gives the root name of the library, in case it is
3227 dnl not installed as the default curses library.  That is how the
3228 dnl wide-character version of ncurses is installed.
3229 AC_DEFUN([CF_NCURSES_LIBS],
3230 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
3231
3232 cf_nculib_root=ifelse($1,,ncurses,$1)
3233         # This works, except for the special case where we find gpm, but
3234         # ncurses is in a nonstandard location via $LIBS, and we really want
3235         # to link gpm.
3236 cf_ncurses_LIBS=""
3237 cf_ncurses_SAVE="$LIBS"
3238 AC_CHECK_LIB(gpm,Gpm_Open,
3239         [AC_CHECK_LIB(gpm,initscr,
3240                 [LIBS="$cf_ncurses_SAVE"],
3241                 [cf_ncurses_LIBS="-lgpm"])])
3242
3243 case "$host_os" in
3244 (freebsd*)
3245         # This is only necessary if you are linking against an obsolete
3246         # version of ncurses (but it should do no harm, since it is static).
3247         if test "$cf_nculib_root" = ncurses ; then
3248                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
3249         fi
3250         ;;
3251 esac
3252
3253 CF_ADD_LIBS($cf_ncurses_LIBS)
3254
3255 if test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no"
3256 then
3257         CF_ADD_LIBS(-l$cf_nculib_root)
3258 else
3259         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
3260                 [#include <${cf_cv_ncurses_header:-curses.h}>],
3261                 [initscr()],
3262                 initscr)
3263 fi
3264
3265 if test -n "$cf_ncurses_LIBS" ; then
3266         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
3267         cf_ncurses_SAVE="$LIBS"
3268         for p in $cf_ncurses_LIBS ; do
3269                 q=`echo "$LIBS" | sed -e "s%$p %%" -e "s%$p$%%"`
3270                 if test "$q" != "$LIBS" ; then
3271                         LIBS="$q"
3272                 fi
3273         done
3274         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
3275                 [initscr(); mousemask(0,0); tigetstr((char *)0);],
3276                 [AC_MSG_RESULT(yes)],
3277                 [AC_MSG_RESULT(no)
3278                  LIBS="$cf_ncurses_SAVE"])
3279 fi
3280
3281 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
3282 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
3283 ])dnl
3284 dnl ---------------------------------------------------------------------------
3285 dnl CF_NCURSES_VERSION version: 17 updated: 2023/01/05 18:54:02
3286 dnl ------------------
3287 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
3288 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
3289 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
3290 AC_DEFUN([CF_NCURSES_VERSION],
3291 [
3292 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
3293 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
3294         cf_cv_ncurses_version=no
3295         cf_tempfile=out$$
3296         rm -f "$cf_tempfile"
3297         AC_TRY_RUN([
3298 $ac_includes_default
3299
3300 #include <${cf_cv_ncurses_header:-curses.h}>
3301
3302 int main(void)
3303 {
3304         FILE *fp = fopen("$cf_tempfile", "w");
3305 #ifdef NCURSES_VERSION
3306 # ifdef NCURSES_VERSION_PATCH
3307         fprintf(fp, "%s.%d\\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
3308 # else
3309         fprintf(fp, "%s\\n", NCURSES_VERSION);
3310 # endif
3311 #else
3312 # ifdef __NCURSES_H
3313         fprintf(fp, "old\\n");
3314 # else
3315         make an error
3316 # endif
3317 #endif
3318         ${cf_cv_main_return:-return}(0);
3319 }],[
3320         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
3321
3322         # This will not work if the preprocessor splits the line after the
3323         # Autoconf token.  The 'unproto' program does that.
3324         cat > "conftest.$ac_ext" <<EOF
3325 #include <${cf_cv_ncurses_header:-curses.h}>
3326 #undef Autoconf
3327 #ifdef NCURSES_VERSION
3328 Autoconf NCURSES_VERSION
3329 #else
3330 #ifdef __NCURSES_H
3331 Autoconf "old"
3332 #endif
3333 ;
3334 #endif
3335 EOF
3336         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
3337         AC_TRY_EVAL(cf_try)
3338         if test -f conftest.out ; then
3339                 cf_out=`sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%' conftest.out`
3340                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
3341                 rm -f conftest.out
3342         fi
3343 ])
3344         rm -f "$cf_tempfile"
3345 ])
3346 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
3347 ])dnl
3348 dnl ---------------------------------------------------------------------------
3349 dnl CF_OBJ_SUBDIR version: 8 updated: 2021/01/01 13:31:04
3350 dnl -------------
3351 dnl Compute the object-directory name from the given model name
3352 AC_DEFUN([CF_OBJ_SUBDIR],
3353 [
3354         case $1 in
3355         (libtool) $2='obj_lo'  ;;
3356         (normal)  $2='objects' ;;
3357         (debug)   $2='obj_g' ;;
3358         (profile) $2='obj_p' ;;
3359         (shared)
3360                 case "$cf_cv_system_name" in
3361                 (cygwin|msys)
3362                         $2='objects' ;;
3363                 (*)
3364                         $2='obj_s' ;;
3365                 esac
3366         esac
3367 ])dnl
3368 dnl ---------------------------------------------------------------------------
3369 dnl CF_PATHSEP version: 8 updated: 2021/01/01 13:31:04
3370 dnl ----------
3371 dnl Provide a value for the $PATH and similar separator (or amend the value
3372 dnl as provided in autoconf 2.5x).
3373 AC_DEFUN([CF_PATHSEP],
3374 [
3375         AC_MSG_CHECKING(for PATH separator)
3376         case "$cf_cv_system_name" in
3377         (os2*)  PATH_SEPARATOR=';'  ;;
3378         (*)     ${PATH_SEPARATOR:=':'}  ;;
3379         esac
3380 ifelse([$1],,,[$1=$PATH_SEPARATOR])
3381         AC_SUBST(PATH_SEPARATOR)
3382         AC_MSG_RESULT($PATH_SEPARATOR)
3383 ])dnl
3384 dnl ---------------------------------------------------------------------------
3385 dnl CF_PATH_SYNTAX version: 18 updated: 2020/12/31 18:40:20
3386 dnl --------------
3387 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
3388 dnl begins with one of the prefix/exec_prefix variables, and then again if the
3389 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
3390 dnl delayed evaluation of those symbols.
3391 AC_DEFUN([CF_PATH_SYNTAX],[
3392 if test "x$prefix" != xNONE; then
3393         cf_path_syntax="$prefix"
3394 else
3395         cf_path_syntax="$ac_default_prefix"
3396 fi
3397
3398 case ".[$]$1" in
3399 (.\[$]\(*\)*|.\'*\'*)
3400         ;;
3401 (..|./*|.\\*)
3402         ;;
3403 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
3404         ;;
3405 (.\[$]\{*prefix\}*|.\[$]\{*dir\}*)
3406         eval $1="[$]$1"
3407         case ".[$]$1" in
3408         (.NONE/*)
3409                 $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
3410                 ;;
3411         esac
3412         ;;
3413 (.no|.NONE/*)
3414         $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
3415         ;;
3416 (*)
3417         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
3418         ;;
3419 esac
3420 ])dnl
3421 dnl ---------------------------------------------------------------------------
3422 dnl CF_PKG_CONFIG version: 12 updated: 2021/10/10 20:18:09
3423 dnl -------------
3424 dnl Check for the package-config program, unless disabled by command-line.
3425 dnl
3426 dnl Sets $PKG_CONFIG to the pathname of the pkg-config program.
3427 AC_DEFUN([CF_PKG_CONFIG],
3428 [
3429 AC_MSG_CHECKING(if you want to use pkg-config)
3430 AC_ARG_WITH(pkg-config,
3431         [  --with-pkg-config{=path} enable/disable use of pkg-config],
3432         [cf_pkg_config=$withval],
3433         [cf_pkg_config=yes])
3434 AC_MSG_RESULT($cf_pkg_config)
3435
3436 case "$cf_pkg_config" in
3437 (no)
3438         PKG_CONFIG=none
3439         ;;
3440 (yes)
3441         CF_ACVERSION_CHECK(2.52,
3442                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
3443                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
3444         ;;
3445 (*)
3446         PKG_CONFIG=$withval
3447         ;;
3448 esac
3449
3450 test -z "$PKG_CONFIG" && PKG_CONFIG=none
3451 if test "$PKG_CONFIG" != none ; then
3452         CF_PATH_SYNTAX(PKG_CONFIG)
3453 elif test "x$cf_pkg_config" != xno ; then
3454         AC_MSG_WARN(pkg-config is not installed)
3455 fi
3456
3457 AC_SUBST(PKG_CONFIG)
3458 ])dnl
3459 dnl ---------------------------------------------------------------------------
3460 dnl CF_POSIX_C_SOURCE version: 12 updated: 2023/02/18 17:41:25
3461 dnl -----------------
3462 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
3463 dnl
3464 dnl     POSIX.1-1990                            _POSIX_SOURCE
3465 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
3466 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
3467 dnl             Bindings Option
3468 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
3469 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
3470 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
3471 dnl
3472 dnl Parameters:
3473 dnl     $1 is the nominal value for _POSIX_C_SOURCE
3474 AC_DEFUN([CF_POSIX_C_SOURCE],
3475 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
3476
3477 if test "$cf_cv_posix_visible" = no; then
3478
3479 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
3480
3481 cf_save_CFLAGS="$CFLAGS"
3482 cf_save_CPPFLAGS="$CPPFLAGS"
3483
3484 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
3485 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
3486
3487 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
3488         CF_MSG_LOG(if the symbol is already defined go no further)
3489         AC_TRY_COMPILE([#include <sys/types.h>],[
3490 #ifndef _POSIX_C_SOURCE
3491 #error _POSIX_C_SOURCE is not defined
3492 #endif],
3493         [cf_cv_posix_c_source=no],
3494         [cf_want_posix_source=no
3495          case .$cf_POSIX_C_SOURCE in
3496          (.[[12]]??*)
3497                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3498                 ;;
3499          (.2)
3500                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3501                 cf_want_posix_source=yes
3502                 ;;
3503          (.*)
3504                 cf_want_posix_source=yes
3505                 ;;
3506          esac
3507          if test "$cf_want_posix_source" = yes ; then
3508                 AC_TRY_COMPILE([#include <sys/types.h>],[
3509 #ifdef _POSIX_SOURCE
3510 #error _POSIX_SOURCE is defined
3511 #endif],[],
3512                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
3513          fi
3514          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
3515          CFLAGS="$cf_trim_CFLAGS"
3516          CPPFLAGS="$cf_trim_CPPFLAGS"
3517          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
3518          CF_MSG_LOG(if the second compile does not leave our definition intact error)
3519          AC_TRY_COMPILE([#include <sys/types.h>],[
3520 #ifndef _POSIX_C_SOURCE
3521 #error _POSIX_C_SOURCE is not defined
3522 #endif],,
3523          [cf_cv_posix_c_source=no])
3524          CFLAGS="$cf_save_CFLAGS"
3525          CPPFLAGS="$cf_save_CPPFLAGS"
3526         ])
3527 ])
3528
3529 if test "$cf_cv_posix_c_source" != no ; then
3530         CFLAGS="$cf_trim_CFLAGS"
3531         CPPFLAGS="$cf_trim_CPPFLAGS"
3532         CF_ADD_CFLAGS($cf_cv_posix_c_source)
3533 fi
3534
3535 fi # cf_cv_posix_visible
3536
3537 ])dnl
3538 dnl ---------------------------------------------------------------------------
3539 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
3540 dnl ----------------
3541 dnl POSIX documents test-macros which an application may set before any system
3542 dnl headers are included to make features available.
3543 dnl
3544 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
3545 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
3546 dnl recent features visible in the system header files unless the application
3547 dnl overrides the corresponding test-macros.  Doing that introduces portability
3548 dnl problems.
3549 dnl
3550 dnl This macro makes a special check for the symbols used for this, to avoid a
3551 dnl conflicting definition.
3552 AC_DEFUN([CF_POSIX_VISIBLE],
3553 [
3554 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
3555 AC_TRY_COMPILE([#include <stdio.h>],[
3556 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
3557         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
3558         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
3559         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
3560 #error conflicting symbols found
3561 #endif
3562 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
3563 ])
3564 ])dnl
3565 dnl ---------------------------------------------------------------------------
3566 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
3567 dnl ----------
3568 dnl Check for archiver "ar".
3569 AC_DEFUN([CF_PROG_AR],[
3570 AC_CHECK_TOOL(AR, ar, ar)
3571 ])
3572 dnl ---------------------------------------------------------------------------
3573 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
3574 dnl -----------
3575 dnl Check for awk, ensure that the check found something.
3576 AC_DEFUN([CF_PROG_AWK],
3577 [
3578 AC_PROG_AWK
3579 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
3580 ])dnl
3581 dnl ---------------------------------------------------------------------------
3582 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
3583 dnl ----------
3584 dnl standard check for CC, plus followup sanity checks
3585 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
3586 AC_DEFUN([CF_PROG_CC],[
3587 CF_ACVERSION_CHECK(2.53,
3588         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
3589          AC_REQUIRE([AC_PROG_CC])],
3590         [])
3591 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
3592 CF_GCC_VERSION
3593 CF_ACVERSION_CHECK(2.52,
3594         [AC_PROG_CC_STDC],
3595         [CF_ANSI_CC_REQD])
3596 CF_CC_ENV_FLAGS
3597 ])dnl
3598 dnl ---------------------------------------------------------------------------
3599 dnl CF_PROG_CC_C_O version: 6 updated: 2021/01/01 13:31:04
3600 dnl --------------
3601 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
3602 dnl the output file can be renamed, and allows for a shell variable that can
3603 dnl be used later.  The parameter is either CC or CXX.  The result is the
3604 dnl cache variable:
3605 dnl     $cf_cv_prog_CC_c_o
3606 dnl     $cf_cv_prog_CXX_c_o
3607 dnl
3608 dnl $1 = compiler
3609 dnl $2 = compiler options, if any
3610 AC_DEFUN([CF_PROG_CC_C_O],
3611 [AC_REQUIRE([AC_PROG_CC])dnl
3612 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
3613 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
3614 [
3615 cat > conftest.$ac_ext <<CF_EOF
3616 int main(void)
3617 {
3618         ${cf_cv_main_return:-return}(0);
3619 }
3620 CF_EOF
3621 # We do the test twice because some compilers refuse to overwrite an
3622 # existing .o file with -o, though they will create one.
3623 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
3624 if AC_TRY_EVAL(ac_try) &&
3625   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
3626 then
3627   eval cf_cv_prog_$1_c_o=yes
3628 else
3629   eval cf_cv_prog_$1_c_o=no
3630 fi
3631 rm -rf ./conftest*
3632 ])dnl
3633 if test "$cf_cv_prog_$1_c_o" = yes; then
3634   AC_MSG_RESULT([yes])
3635 else
3636   AC_MSG_RESULT([no])
3637 fi
3638 ])dnl
3639 dnl ---------------------------------------------------------------------------
3640 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
3641 dnl -------------
3642 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
3643 dnl This macro adds a check to ensure the script found something.
3644 AC_DEFUN([CF_PROG_EGREP],
3645 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
3646         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
3647                 then ac_cv_prog_egrep='grep -E'
3648                 else ac_cv_prog_egrep='egrep'
3649         fi])
3650         EGREP=$ac_cv_prog_egrep
3651         AC_SUBST([EGREP])
3652         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
3653 ])dnl
3654 dnl ---------------------------------------------------------------------------
3655 dnl CF_PROG_EXT version: 15 updated: 2021/01/02 09:31:20
3656 dnl -----------
3657 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
3658 AC_DEFUN([CF_PROG_EXT],
3659 [
3660 AC_REQUIRE([CF_CHECK_CACHE])
3661 case "$cf_cv_system_name" in
3662 (os2*)
3663         CFLAGS="$CFLAGS -Zmt"
3664         CF_APPEND_TEXT(CPPFLAGS,-D__ST_MT_ERRNO__)
3665         CXXFLAGS="$CXXFLAGS -Zmt"
3666         # autoconf's macro sets -Zexe and suffix both, which conflict:w
3667         LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
3668         ac_cv_exeext=.exe
3669         ;;
3670 esac
3671
3672 AC_EXEEXT
3673 AC_OBJEXT
3674
3675 PROG_EXT="$EXEEXT"
3676 AC_SUBST(PROG_EXT)
3677 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT",[Define to the program extension (normally blank)])
3678 ])dnl
3679 dnl ---------------------------------------------------------------------------
3680 dnl CF_PROG_GNAT version: 12 updated: 2021/01/02 17:09:14
3681 dnl ------------
3682 dnl Check for gnat/gnatmake/etc, ensure that the toolset is complete.
3683 AC_DEFUN([CF_PROG_GNAT],[
3684 for cf_prog_gnat in gnat gnatmake gprconfig gprbuild
3685 do
3686         CF_UPPER(cf_upper_prog_gnat,${cf_prog_gnat})
3687
3688         unset ac_cv_path_cf_TEMP_gnat
3689         unset cf_TEMP_gnat
3690         AC_PATH_PROG(cf_TEMP_gnat,$cf_prog_gnat,no)
3691         eval "cf_cv_PATH_$cf_upper_prog_gnat=[$]ac_cv_path_cf_TEMP_gnat"
3692
3693         if test "x$cf_TEMP_gnat" != xno; then
3694                 unset cf_cv_gnat_version
3695                 unset cf_TEMP_gnat
3696                 CF_GNAT_VERSION(cf_TEMP_gnat,$cf_prog_gnat)
3697         fi
3698         eval "cf_cv_VERSION_$cf_upper_prog_gnat=[$]cf_TEMP_gnat"
3699
3700         unset cf_TEMP_gnat
3701         unset cf_cv_gnat_version
3702         unset ac_cv_path_cf_TEMP_gnat
3703 done
3704
3705 if test "x$cf_cv_VERSION_GNATMAKE" = "xno"; then
3706         cf_ada_make=
3707         cf_cv_prog_gnat_correct=no
3708 else
3709         cf_ada_make=gnatmake
3710         if test "x$cf_cv_VERSION_GPRCONFIG" = "xno"; then
3711                 # gprconfig is newer than gnatmake; we can continue...
3712                 cf_ada_config="##"
3713         else
3714                 rm -rf ./conftest* ./*~conftest*
3715                 if mkdir conftest.src
3716                 then
3717                         cf_ada_config=""
3718                         cd conftest.src
3719                         for cf_gprconfig in Ada C
3720                         do
3721                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
3722                                 if test "$cf_gprconfig" = C
3723                                 then
3724                                         for cf_gprconfig_param in \
3725                                                 "$cf_gprconfig,,,,GNATGCC" \
3726                                                 "$cf_gprconfig,,,,GCC" \
3727                                                 "$cf_gprconfig"
3728                                         do
3729                                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
3730                                                 test -n "$cf_gprconfig_value" && break
3731                                         done
3732                                 else
3733                                         cf_gprconfig_param=$cf_gprconfig
3734                                         cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
3735                                 fi
3736                                 if test -n "$cf_gprconfig_value"
3737                                 then
3738                                         eval "cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value"
3739                                         AC_MSG_RESULT($cf_gprconfig_value)
3740                                 else
3741                                         AC_MSG_RESULT(missing)
3742                                         cf_ada_config="#"
3743                                         break
3744                                 fi
3745                         done
3746                         cd ..
3747                         rm -rf ./conftest* ./*~conftest*
3748                 fi
3749         fi
3750         if test "x$cf_ada_config" != "x#"
3751         then
3752                 CF_GNAT_VERSION
3753                 CF_CHECK_GNAT_VERSION
3754                 AC_CHECK_PROG(M4_exists, m4, yes, no)
3755                 if test "$ac_cv_prog_M4_exists" = no; then
3756                         cf_cv_prog_gnat_correct=no
3757                         AC_MSG_WARN(Ada95 binding required program m4 not found. Ada95 binding disabled)
3758                 fi
3759                 if test "$cf_cv_prog_gnat_correct" = yes; then
3760                         AC_MSG_CHECKING(if GNAT works)
3761                         CF_GNAT_TRY_RUN([procedure conftest;],
3762 [with Text_IO;
3763 with GNAT.OS_Lib;
3764 procedure conftest is
3765 begin
3766    Text_IO.Put ("Hello World");
3767    Text_IO.New_Line;
3768    GNAT.OS_Lib.OS_Exit (0);
3769 end conftest;],
3770 [cf_cv_prog_gnat_correct=yes],
3771 [cf_cv_prog_gnat_correct=no])
3772                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
3773                 fi
3774         else
3775                 cf_cv_prog_gnat_correct=no
3776         fi
3777 fi
3778
3779 AC_SUBST(cf_ada_make)
3780 AC_SUBST(cf_ada_config)
3781 AC_SUBST(cf_ada_config_Ada)
3782 AC_SUBST(cf_ada_config_C)
3783 ])dnl
3784 dnl ---------------------------------------------------------------------------
3785 dnl CF_PROG_INSTALL version: 10 updated: 2021/01/04 19:33:05
3786 dnl ---------------
3787 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
3788 dnl misc/tabset install won't work properly.  Usually this happens only when
3789 dnl using the fallback mkinstalldirs script
3790 AC_DEFUN([CF_PROG_INSTALL],
3791 [AC_PROG_INSTALL
3792 case $INSTALL in
3793 (/*)
3794         ;;
3795 (*)
3796         CF_DIRNAME(cf_dir,$INSTALL)
3797         test -z "$cf_dir" && cf_dir=.
3798         INSTALL="`cd \"$cf_dir\" && pwd`"/"`echo "$INSTALL" | sed -e 's%^.*/%%'`"
3799         ;;
3800 esac
3801 ])dnl
3802 dnl ---------------------------------------------------------------------------
3803 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
3804 dnl ------------
3805 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
3806 dnl option if it is supported.
3807 AC_DEFUN([CF_PROG_LN_S],[
3808 AC_PROG_LN_S
3809 AC_MSG_CHECKING(if $LN_S -f options work)
3810
3811 rm -f conf$$.src conf$$dst
3812 echo >conf$$.dst
3813 echo first >conf$$.src
3814 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
3815         cf_prog_ln_sf=yes
3816 else
3817         cf_prog_ln_sf=no
3818 fi
3819 rm -f conf$$.dst conf$$src
3820 AC_MSG_RESULT($cf_prog_ln_sf)
3821
3822 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
3823 ])dnl
3824 dnl ---------------------------------------------------------------------------
3825 dnl CF_REMOVE_CFLAGS version: 3 updated: 2021/09/05 17:25:40
3826 dnl ----------------
3827 dnl Remove a given option from CFLAGS/CPPFLAGS
3828 dnl $1 = option to remove
3829 dnl $2 = variable to update
3830 dnl $3 = nonempty to allow verbose message
3831 define([CF_REMOVE_CFLAGS],
3832 [
3833 cf_tmp_cflag=`echo "x$1" | sed -e 's/^.//' -e 's/=.*//'`
3834 while true
3835 do
3836         cf_old_cflag=`echo "x[$]$2" | sed -e 's/^.//' -e 's/[[  ]][[    ]]*-/ -/g' -e "s%$cf_tmp_cflag\\(=[[^   ]][[^   ]]*\\)\?%%" -e 's/^[[   ]]*//' -e 's%[[ ]][[ ]]*-D% -D%g' -e 's%[[ ]][[ ]]*-I% -I%g'`
3837         test "[$]$2" != "$cf_old_cflag" || break
3838         ifelse([$3],,,[CF_VERBOSE(removing old option $1 from $2)])
3839         $2="$cf_old_cflag"
3840 done
3841 ])dnl
3842 dnl ---------------------------------------------------------------------------
3843 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
3844 dnl ----------------
3845 dnl Remove all -U and -D options that refer to the given symbol from a list
3846 dnl of C compiler options.  This works around the problem that not all
3847 dnl compilers process -U and -D options from left-to-right, so a -U option
3848 dnl cannot be used to cancel the effect of a preceding -D option.
3849 dnl
3850 dnl $1 = target (which could be the same as the source variable)
3851 dnl $2 = source (including '$')
3852 dnl $3 = symbol to remove
3853 define([CF_REMOVE_DEFINE],
3854 [
3855 $1=`echo "$2" | \
3856         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
3857                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
3858 ])dnl
3859 dnl ---------------------------------------------------------------------------
3860 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
3861 dnl -------------
3862 dnl Remove the given library from the symbol
3863 dnl
3864 dnl $1 = target (which could be the same as the source variable)
3865 dnl $2 = source (including '$')
3866 dnl $3 = library to remove
3867 define([CF_REMOVE_LIB],
3868 [
3869 # remove $3 library from $2
3870 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
3871 ])dnl
3872 dnl ---------------------------------------------------------------------------
3873 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
3874 dnl ---------------------
3875 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
3876 dnl $1 = name of current macro
3877 define([CF_RESTORE_XTRA_FLAGS],
3878 [
3879 LIBS="$cf_save_LIBS_$1"
3880 CFLAGS="$cf_save_CFLAGS_$1"
3881 CPPFLAGS="$cf_save_CPPFLAGS_$1"
3882 ])dnl
3883 dnl ---------------------------------------------------------------------------
3884 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
3885 dnl ------------------
3886 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
3887 dnl and libraries which do not update those variables.
3888 dnl
3889 dnl $1 = name of current macro
3890 define([CF_SAVE_XTRA_FLAGS],
3891 [
3892 cf_save_LIBS_$1="$LIBS"
3893 cf_save_CFLAGS_$1="$CFLAGS"
3894 cf_save_CPPFLAGS_$1="$CPPFLAGS"
3895 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
3896 for cf_X_CFLAGS in $X_CFLAGS
3897 do
3898         case "x$cf_X_CFLAGS" in
3899         x-[[IUD]]*)
3900                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
3901                 ;;
3902         *)
3903                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
3904                 ;;
3905         esac
3906 done
3907 ])dnl
3908 dnl ---------------------------------------------------------------------------
3909 dnl CF_SHARED_OPTS version: 107 updated: 2021/09/04 06:47:34
3910 dnl --------------
3911 dnl --------------
3912 dnl Attempt to determine the appropriate CC/LD options for creating a shared
3913 dnl library.
3914 dnl
3915 dnl Notes:
3916 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
3917 dnl the build-tree, i.e., by making use of the libraries that are compiled in
3918 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
3919 dnl shared library since that can lead to unexpected results at runtime.
3920 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
3921 dnl libraries are compiled in ../../lib
3922 dnl
3923 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
3924 dnl to install symbolic links to the rel/abi versions of shared libraries.
3925 dnl
3926 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
3927 dnl version when making symbolic links.
3928 dnl
3929 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
3930 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
3931 dnl (ex: libncurses.so.<ver>).
3932 dnl
3933 dnl Some loaders leave 'so_locations' lying around.  It is nice to clean up.
3934 AC_DEFUN([CF_SHARED_OPTS],
3935 [
3936         AC_REQUIRE([CF_LD_RPATH_OPT])
3937
3938         RM_SHARED_OPTS=
3939         LOCAL_LDFLAGS=
3940         LOCAL_LDFLAGS2=
3941         LD_SHARED_OPTS=
3942         INSTALL_LIB="-m 644"
3943         : ${rel_builddir:=.}
3944
3945         shlibdir=$libdir
3946         AC_SUBST(shlibdir)
3947
3948         MAKE_DLLS="#"
3949         AC_SUBST(MAKE_DLLS)
3950
3951         cf_cv_do_symlinks=no
3952         cf_ld_rpath_opt=
3953         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
3954
3955         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
3956         AC_ARG_WITH(shlib-version,
3957         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
3958         [test -z "$withval" && withval=auto
3959         case "$withval" in
3960         (yes)
3961                 cf_cv_shlib_version=auto
3962                 ;;
3963         (rel|abi|auto)
3964                 cf_cv_shlib_version=$withval
3965                 ;;
3966         (*)
3967                 AC_MSG_RESULT($withval)
3968                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
3969                 ;;
3970         esac
3971         ],[cf_cv_shlib_version=auto])
3972         AC_MSG_RESULT($cf_cv_shlib_version)
3973
3974         cf_cv_rm_so_locs=no
3975         cf_try_cflags=
3976
3977         # Some less-capable ports of gcc support only -fpic
3978         CC_SHARED_OPTS=
3979
3980         cf_try_fPIC=no
3981         if test "$GCC" = yes
3982         then
3983                 cf_try_fPIC=yes
3984         else
3985                 case "$cf_cv_system_name" in
3986                 (*linux*)       # e.g., PGI compiler
3987                         cf_try_fPIC=yes
3988                         ;;
3989                 esac
3990         fi
3991
3992         if test "$cf_try_fPIC" = yes
3993         then
3994                 AC_MSG_CHECKING(which $CC option to use)
3995                 cf_save_CFLAGS="$CFLAGS"
3996                 for CC_SHARED_OPTS in -fPIC -fpic ''
3997                 do
3998                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
3999                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
4000                 done
4001                 AC_MSG_RESULT($CC_SHARED_OPTS)
4002                 CFLAGS="$cf_save_CFLAGS"
4003         fi
4004
4005         cf_cv_shlib_version_infix=no
4006
4007         case "$cf_cv_system_name" in
4008         (aix4.[3-9]*|aix[[5-7]]*)
4009                 if test "$GCC" = yes; then
4010                         CC_SHARED_OPTS='-Wl,-brtl'
4011                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
4012                 else
4013                         CC_SHARED_OPTS='-brtl'
4014                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
4015                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
4016                 fi
4017                 ;;
4018         (beos*)
4019                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
4020                 ;;
4021         (cygwin*)
4022                 CC_SHARED_OPTS=
4023                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
4024                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
4025                 cf_cv_shlib_version=cygdll
4026                 cf_cv_shlib_version_infix=cygdll
4027                 shlibdir=$bindir
4028                 MAKE_DLLS=
4029                 cat >mk_shared_lib.sh <<-CF_EOF
4030                 #!$SHELL
4031                 SHARED_LIB=\[$]1
4032                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
4033                 shift
4034                 cat <<-EOF
4035                 Linking shared library
4036                 ** SHARED_LIB \[$]SHARED_LIB
4037                 ** IMPORT_LIB \[$]IMPORT_LIB
4038 EOF
4039                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
4040 CF_EOF
4041                 chmod +x mk_shared_lib.sh
4042                 ;;
4043         (msys*)
4044                 CC_SHARED_OPTS=
4045                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
4046                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
4047                 cf_cv_shlib_version=msysdll
4048                 cf_cv_shlib_version_infix=msysdll
4049                 shlibdir=$bindir
4050                 MAKE_DLLS=
4051                 cat >mk_shared_lib.sh <<-CF_EOF
4052                 #!$SHELL
4053                 SHARED_LIB=\[$]1
4054                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
4055                 shift
4056                 cat <<-EOF
4057                 Linking shared library
4058                 ** SHARED_LIB \[$]SHARED_LIB
4059                 ** IMPORT_LIB \[$]IMPORT_LIB
4060 EOF
4061                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
4062 CF_EOF
4063                 chmod +x mk_shared_lib.sh
4064                 ;;
4065         (darwin*)
4066                 cf_try_cflags="no-cpp-precomp"
4067                 CC_SHARED_OPTS="-dynamic"
4068                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
4069                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
4070                 cf_cv_shlib_version_infix=yes
4071                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
4072                         cf_save_LDFLAGS=$LDFLAGS
4073                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
4074                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
4075                                 LDFLAGS=$cf_save_LDFLAGS])
4076                 if test "$cf_cv_ldflags_search_paths_first" = yes; then
4077                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
4078                 fi
4079                 ;;
4080         (haiku*)
4081                 CF_SHARED_SONAME
4082                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
4083                 ;;
4084         (hpux[[7-8]]*)
4085                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
4086                 if test "$GCC" != yes; then
4087                         CC_SHARED_OPTS='+Z'
4088                 fi
4089                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
4090                 INSTALL_LIB="-m 555"
4091                 ;;
4092         (hpux*)
4093                 # (tested with gcc 2.7.2 -- I don't have c89)
4094                 if test "$GCC" = yes; then
4095                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
4096                 else
4097                         CC_SHARED_OPTS='+Z'
4098                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
4099                 fi
4100                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
4101                 # HP-UX shared libraries must be executable, and should be
4102                 # readonly to exploit a quirk in the memory manager.
4103                 INSTALL_LIB="-m 555"
4104                 ;;
4105         (interix*)
4106                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
4107                 if test "$cf_cv_shlib_version" = rel; then
4108                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
4109                 else
4110                         cf_shared_soname='`basename $[@]`'
4111                 fi
4112                 CC_SHARED_OPTS=
4113                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
4114                 ;;
4115         (irix*)
4116                 if test "$cf_cv_enable_rpath" = yes ; then
4117                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
4118                 fi
4119                 # tested with IRIX 5.2 and 'cc'.
4120                 if test "$GCC" != yes; then
4121                         CC_SHARED_OPTS='-KPIC'
4122                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
4123                 else
4124                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
4125                 fi
4126                 cf_cv_rm_so_locs=yes
4127                 ;;
4128         (linux*|gnu*|k*bsd*-gnu)
4129                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
4130                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
4131                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
4132                 fi
4133                 if test "$cf_cv_enable_rpath" = yes ; then
4134                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
4135                 fi
4136                 CF_SHARED_SONAME
4137                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
4138                 ;;
4139         (mingw*msvc*)
4140                 cf_cv_shlib_version=msvcdll
4141                 cf_cv_shlib_version_infix=msvcdll
4142                 shlibdir=$bindir
4143                 MAKE_DLLS=
4144                 if test "$DFT_LWR_MODEL" = "shared" ; then
4145                         LOCAL_LDFLAGS="-link -dll"
4146                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
4147                         EXTRA_LDFLAGS="-link -dll $EXTRA_LDFLAGS"
4148                 fi
4149                 CC_SHARED_OPTS=
4150                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ ${LD} [$]{CFLAGS}'
4151                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.lib"
4152                 cat >mk_shared_lib.sh <<-CF_EOF
4153                 #!$SHELL
4154                 SHARED_LIB=\[$]1
4155                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.lib/'\`
4156                 shift
4157                 my_ld=\[$]1
4158                 shift
4159                 cat <<-EOF
4160                 Linking shared library
4161                 ** SHARED LIB \$SHARED_LIB
4162                 ** IMPORT_LIB \$IMPORT_LIB
4163 EOF
4164                 args=\$(echo \[$]* | sed -E "s#-l(\w*)#\1.dll.lib#g" | sed -E "s#-L(\w*)#-LIBPATH:\1#g")
4165                 exec \$my_ld -DLL -IMPLIB:"\${IMPORT_LIB}" -OUT:"\${SHARED_LIB}" ${LDFLAGS} \$args
4166                 mv "\${IMPORT_LIB}" "\${IMPORT_LIB}"
4167 CF_EOF
4168                 chmod +x mk_shared_lib.sh
4169                 cat >mk_prog.sh <<-CF_EOF
4170                 #!$SHELL
4171                 shift
4172                 # Ignore first argument (compiler) and use LD (link.exe) unconditionally
4173                 LD="[$]LD"
4174                 clopts=()
4175                 ldopts=("/subsystem:console")
4176                 libs=()
4177                 isdll=0
4178                 while test \[$]# -gt 0; do
4179                         case "\[$]1" in
4180                                 -link)
4181                                         # ignore -link argument
4182                                         ;;
4183                                 -M[[TD]] | -M[[TD]]d)
4184                                         # ignore runtime-library option
4185                                         ;;
4186                                 -dll)
4187                                         isdll=1
4188                                         ;;
4189                                 -W* | -w*)
4190                                         # ignore warnings
4191                                         ;;
4192                                 -D*)
4193                                         clopts+=("\[$]1")
4194                                         ;;
4195                                 -I*)
4196                                         clopts+=("\[$]1")
4197                                         ;;
4198                                 -l*)
4199                                         libs+=("\`echo \"\[$]1\" | sed \"s/^-l//\"\`")
4200                                         ;;
4201                                 -L*)
4202                                         ldopts+=("\`echo \"\[$]1\" | sed \"s/^-L/-LIBPATH:/\"\`")
4203                                         ;;
4204                                 *.obj | *.o)
4205                                         ldopts+=("\[$]1")
4206                                         ;;
4207                                 -Wl,*)
4208                                         for linkarg in \`echo '\[$]1' | sed -e 's/-Wl,//' -e 's/,/ /'\`; do
4209                                                 ldopts+=("\[$]{linkarg}")
4210                                         done
4211                                         ;;
4212                                 *.lib)
4213                                         ldopts+=("\[$]1")
4214                                         ;;
4215                                 -o)
4216                                         shift
4217                                         ldopts+=("-out:\[$]1")
4218                                         ;;
4219                                 *)
4220                                         clopts+=("\[$]1")
4221                                         ldopts+=("\[$]1")
4222                                         ;;
4223                         esac
4224                         shift
4225                 done
4226                 if [[ "\$isdll" -ne 0 ]]; then
4227                         for lib in \[$]{libs[[*]]}; do
4228                                 ldopts+=("\[$]lib.dll.lib")
4229                         done
4230                 else
4231                         for lib in \[$]{libs[[*]]}; do
4232                                 ldopts+=("\[$]lib.lib")
4233                         done
4234                 fi
4235                 cat <<-EOF
4236                 Creating program
4237                 ** ld options:   "\[$]{ldopts[[@]]}"
4238 EOF
4239                 exec \[$]LD \[$]{ldopts[[@]]}
4240 CF_EOF
4241                 chmod +x mk_prog.sh
4242                 LINK_PROGS="$SHELL ${rel_builddir}/mk_prog.sh"
4243                 LINK_TESTS="$SHELL ${rel_builddir}/mk_prog.sh"
4244                 ;;
4245         (mingw*)
4246                 cf_cv_shlib_version=mingw
4247                 cf_cv_shlib_version_infix=mingw
4248                 shlibdir=$bindir
4249                 MAKE_DLLS=
4250                 if test "$DFT_LWR_MODEL" = "shared" ; then
4251                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
4252                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
4253                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
4254                 fi
4255                 CC_SHARED_OPTS=
4256                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
4257                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
4258                 cat >mk_shared_lib.sh <<-CF_EOF
4259                 #!$SHELL
4260                 SHARED_LIB=\[$]1
4261                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
4262                 shift
4263                 cat <<-EOF
4264                 Linking shared library
4265                 ** SHARED_LIB \[$]SHARED_LIB
4266                 ** IMPORT_LIB \[$]IMPORT_LIB
4267 EOF
4268                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
4269 CF_EOF
4270                 chmod +x mk_shared_lib.sh
4271                 ;;
4272         (openbsd[[2-9]].*|mirbsd*)
4273                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
4274                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
4275                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
4276                 fi
4277                 if test "$cf_cv_enable_rpath" = yes ; then
4278                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
4279                 fi
4280                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
4281                 CF_SHARED_SONAME
4282                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
4283                 ;;
4284         (nskJ*)
4285                 CC_SHARED_OPTS=
4286                 MK_SHARED_LIB='${LD} -Wshared -Weld=-export_all -o $[@]'
4287                 ;;
4288         (nskL*)
4289                 CC_SHARED_OPTS=
4290                 MK_SHARED_LIB='${LD} -Wshared -Wxld=-export_all -o $[@]'
4291                 ;;
4292         (nto-qnx*|openbsd*|freebsd[[12]].*)
4293                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
4294                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
4295                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
4296                 ;;
4297         (dragonfly*|freebsd*)
4298                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
4299                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
4300                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
4301                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
4302                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
4303                 fi
4304                 CF_SHARED_SONAME
4305                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
4306                 ;;
4307         (netbsd*)
4308                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
4309                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
4310                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
4311                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
4312                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
4313                         if test "$cf_cv_shlib_version" = auto; then
4314                         if test -f /usr/libexec/ld.elf_so; then
4315                                 cf_cv_shlib_version=abi
4316                         else
4317                                 cf_cv_shlib_version=rel
4318                         fi
4319                         fi
4320                         CF_SHARED_SONAME
4321                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
4322                 else
4323                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -o $[@]'
4324                 fi
4325                 ;;
4326         (osf*|mls+*)
4327                 # tested with OSF/1 V3.2 and 'cc'
4328                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
4329                 # link with shared libs).
4330                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
4331                 case "$host_os" in
4332                 (osf4*)
4333                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
4334                         ;;
4335                 esac
4336                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
4337                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
4338                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
4339                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
4340                 fi
4341                 cf_cv_rm_so_locs=yes
4342                 ;;
4343         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
4344                 # tested with osr5.0.5
4345                 if test "$GCC" != yes; then
4346                         CC_SHARED_OPTS='-belf -KPIC'
4347                 fi
4348                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
4349                 if test "$cf_cv_enable_rpath" = yes ; then
4350                         # only way is to set LD_RUN_PATH but no switch for it
4351                         RUN_PATH=$libdir
4352                 fi
4353                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
4354                 LINK_PROGS='LD_RUN_PATH=${libdir}'
4355                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
4356                 ;;
4357         (sunos4*)
4358                 # tested with SunOS 4.1.1 and gcc 2.7.0
4359                 if test "$GCC" != yes; then
4360                         CC_SHARED_OPTS='-KPIC'
4361                 fi
4362                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
4363                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
4364                 ;;
4365         (solaris2*)
4366                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
4367                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
4368                 if test "$DFT_LWR_MODEL" = "shared" ; then
4369                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
4370                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
4371                 fi
4372                 if test "$cf_cv_enable_rpath" = yes ; then
4373                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
4374                 fi
4375                 CF_SHARED_SONAME
4376                 if test "$GCC" != yes; then
4377                         cf_save_CFLAGS="$CFLAGS"
4378                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
4379                         do
4380                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
4381                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\\n");],[break])
4382                         done
4383                         CFLAGS="$cf_save_CFLAGS"
4384                         CC_SHARED_OPTS=$cf_shared_opts
4385                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
4386                 else
4387                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
4388                 fi
4389                 ;;
4390         (sysv5uw7*|unix_sv*)
4391                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
4392                 if test "$GCC" != yes; then
4393                         CC_SHARED_OPTS='-KPIC'
4394                 fi
4395                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
4396                 ;;
4397         (*)
4398                 CC_SHARED_OPTS='unknown'
4399                 MK_SHARED_LIB='echo unknown'
4400                 ;;
4401         esac
4402
4403         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
4404         case "$cf_cv_shlib_version" in
4405         (rel|abi)
4406                 case "$MK_SHARED_LIB" in
4407                 (*'-o $[@]')
4408                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
4409                         ;;
4410                 (*)
4411                         AC_MSG_WARN(ignored --with-shlib-version)
4412                         ;;
4413                 esac
4414                 ;;
4415         esac
4416
4417         if test -n "$cf_try_cflags"
4418         then
4419 cat > conftest.$ac_ext <<EOF
4420 #line __oline__ "${as_me:-configure}"
4421 #include <stdio.h>
4422 int main(int argc, char *argv[[]])
4423 {
4424         printf("hello\\n");
4425         return (argv[[argc-1]] == 0) ;
4426 }
4427 EOF
4428                 cf_save_CFLAGS="$CFLAGS"
4429                 for cf_opt in $cf_try_cflags
4430                 do
4431                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
4432                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
4433                         if AC_TRY_EVAL(ac_compile); then
4434                                 AC_MSG_RESULT(yes)
4435                                 cf_save_CFLAGS="$CFLAGS"
4436                         else
4437                                 AC_MSG_RESULT(no)
4438                         fi
4439                 done
4440                 CFLAGS="$cf_save_CFLAGS"
4441         fi
4442
4443
4444         # RPATH_LIST is a colon-separated list of directories
4445         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
4446         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
4447
4448         test "$cf_cv_rm_so_locs" = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
4449
4450         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
4451         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
4452
4453         AC_SUBST(CC_SHARED_OPTS)
4454         AC_SUBST(LD_RPATH_OPT)
4455         AC_SUBST(LD_SHARED_OPTS)
4456         AC_SUBST(MK_SHARED_LIB)
4457         AC_SUBST(RM_SHARED_OPTS)
4458
4459         AC_SUBST(LINK_PROGS)
4460         AC_SUBST(LINK_TESTS)
4461
4462         AC_SUBST(EXTRA_LDFLAGS)
4463         AC_SUBST(LOCAL_LDFLAGS)
4464         AC_SUBST(LOCAL_LDFLAGS2)
4465
4466         AC_SUBST(INSTALL_LIB)
4467         AC_SUBST(RPATH_LIST)
4468 ])dnl
4469 dnl ---------------------------------------------------------------------------
4470 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
4471 dnl ----------------
4472 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
4473 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
4474 dnl option.
4475 dnl
4476 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
4477 dnl If missing, use "rel".
4478 define([CF_SHARED_SONAME],
4479 [
4480         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
4481         if test "$cf_cv_shlib_version" = rel; then
4482                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
4483         else
4484                 cf_cv_shared_soname='`basename $[@]`'
4485         fi
4486 ])
4487 dnl ---------------------------------------------------------------------------
4488 dnl CF_STRIP_G_OPT version: 4 updated: 2021/01/02 09:31:20
4489 dnl --------------
4490 dnl     Remove "-g" option from the compiler options
4491 AC_DEFUN([CF_STRIP_G_OPT],
4492 [$1=`echo "${$1}" | CF__SED_TRIMBLANKS(-e 's%-g %%' -e 's%-g$%%')`])dnl
4493 dnl ---------------------------------------------------------------------------
4494 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
4495 dnl --------------
4496 dnl Construct a search-list for a nonstandard header/lib-file
4497 dnl     $1 = the variable to return as result
4498 dnl     $2 = the package name
4499 dnl     $3 = the subdirectory, e.g., bin, include or lib
4500 AC_DEFUN([CF_SUBDIR_PATH],
4501 [
4502 $1=
4503
4504 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
4505
4506 for cf_subdir_prefix in \
4507         /usr \
4508         /usr/local \
4509         /usr/pkg \
4510         /opt \
4511         /opt/local \
4512         [$]HOME
4513 do
4514         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
4515 done
4516 ])dnl
4517 dnl ---------------------------------------------------------------------------
4518 dnl CF_TERM_HEADER version: 6 updated: 2021/01/02 09:31:20
4519 dnl --------------
4520 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
4521 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
4522 dnl but some packagers change this, breaking various applications.
4523 AC_DEFUN([CF_TERM_HEADER],[
4524 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
4525 case "${cf_cv_ncurses_header}" in
4526 (*/ncurses.h|*/ncursesw.h)
4527         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
4528         ;;
4529 (*)
4530         cf_term_header=term.h
4531         ;;
4532 esac
4533
4534 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
4535 do
4536 AC_TRY_COMPILE([#include <stdio.h>
4537 #include <${cf_cv_ncurses_header:-curses.h}>
4538 #include <$cf_test>
4539 ],[int x = auto_left_margin; (void)x],[
4540         cf_cv_term_header="$cf_test"],[
4541         cf_cv_term_header=unknown
4542         ])
4543         test "$cf_cv_term_header" != unknown && break
4544 done
4545 ])
4546
4547 # Set definitions to allow ifdef'ing to accommodate subdirectories
4548
4549 case "$cf_cv_term_header" in
4550 (*term.h)
4551         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
4552         ;;
4553 esac
4554
4555 case "$cf_cv_term_header" in
4556 (ncurses/term.h)
4557         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
4558         ;;
4559 (ncursesw/term.h)
4560         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
4561         ;;
4562 esac
4563 ])dnl
4564 dnl ---------------------------------------------------------------------------
4565 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
4566 dnl ---------------
4567 dnl Define a top_builddir symbol, for applications that need an absolute path.
4568 AC_DEFUN([CF_TOP_BUILDDIR],
4569 [
4570 top_builddir=ifelse($1,,`pwd`,$1)
4571 AC_SUBST(top_builddir)
4572 ])dnl
4573 dnl ---------------------------------------------------------------------------
4574 dnl CF_TRY_XOPEN_SOURCE version: 4 updated: 2022/09/10 15:16:16
4575 dnl -------------------
4576 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
4577 dnl can define it successfully.
4578 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
4579 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
4580         AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,
4581         [cf_cv_xopen_source=no],
4582         [cf_save="$CPPFLAGS"
4583          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
4584          AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,
4585                 [cf_cv_xopen_source=no],
4586                 [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
4587                 CPPFLAGS="$cf_save"
4588         ])
4589 ])
4590
4591 if test "$cf_cv_xopen_source" != no ; then
4592         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
4593         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
4594         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
4595         CF_APPEND_CFLAGS($cf_temp_xopen_source)
4596 fi
4597 ])
4598 dnl ---------------------------------------------------------------------------
4599 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
4600 dnl --------
4601 dnl Make an uppercase version of a variable
4602 dnl $1=uppercase($2)
4603 AC_DEFUN([CF_UPPER],
4604 [
4605 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4606 ])dnl
4607 dnl ---------------------------------------------------------------------------
4608 dnl CF_UTF8_LIB version: 10 updated: 2023/01/11 04:05:23
4609 dnl -----------
4610 dnl Check for multibyte support, and if not found, utf8 compatibility library
4611 AC_DEFUN([CF_UTF8_LIB],
4612 [
4613 AC_HAVE_HEADERS(wchar.h)
4614 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
4615         cf_save_LIBS="$LIBS"
4616         AC_TRY_LINK([
4617 $ac_includes_default
4618 #ifdef HAVE_WCHAR_H
4619 #include <wchar.h>
4620 #endif
4621 ],[putwc(0,0);],
4622         [cf_cv_utf8_lib=yes],
4623         [CF_FIND_LINKAGE([
4624 #include <libutf8.h>],[putwc(0,0);],utf8,
4625                 [cf_cv_utf8_lib=add-on],
4626                 [cf_cv_utf8_lib=no])
4627 ])])
4628
4629 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
4630 # ncurses/ncursesw:
4631 if test "$cf_cv_utf8_lib" = "add-on" ; then
4632         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
4633         CF_ADD_INCDIR($cf_cv_header_path_utf8)
4634         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
4635         CF_ADD_LIBS($cf_cv_library_file_utf8)
4636 fi
4637 ])dnl
4638 dnl ---------------------------------------------------------------------------
4639 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
4640 dnl ----------
4641 dnl Use AC_VERBOSE w/o the warnings
4642 AC_DEFUN([CF_VERBOSE],
4643 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
4644 CF_MSG_LOG([$1])
4645 ])dnl
4646 dnl ---------------------------------------------------------------------------
4647 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
4648 dnl ---------------
4649 dnl Check for compiler-support for weak symbols.
4650 dnl This works with "recent" gcc.
4651 AC_DEFUN([CF_WEAK_SYMBOLS],[
4652 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
4653
4654 AC_TRY_COMPILE([
4655 #include <stdio.h>],
4656 [
4657 #if defined(__GNUC__)
4658 #  if defined __USE_ISOC99
4659 #    define _cat_pragma(exp)    _Pragma(#exp)
4660 #    define _weak_pragma(exp)   _cat_pragma(weak name)
4661 #  else
4662 #    define _weak_pragma(exp)
4663 #  endif
4664 #  define _declare(name)        __extension__ extern __typeof__(name) name
4665 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
4666 #endif
4667
4668 weak_symbol(fopen);
4669 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
4670 ])
4671 ])dnl
4672 dnl ---------------------------------------------------------------------------
4673 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
4674 dnl --------------------
4675 dnl Command-line option to specify the Ada95 compiler.
4676 AC_DEFUN([CF_WITH_ADA_COMPILER],[
4677 AC_MSG_CHECKING(for ada-compiler)
4678 AC_ARG_WITH(ada-compiler,
4679         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
4680         [cf_ada_compiler=$withval],
4681         [cf_ada_compiler=gnatmake])
4682 AC_SUBST(cf_ada_compiler)
4683 AC_MSG_RESULT($cf_ada_compiler)
4684 ])dnl
4685 dnl ---------------------------------------------------------------------------
4686 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
4687 dnl -------------------
4688 dnl Command-line option to specify where Ada includes will install.
4689 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
4690 AC_MSG_CHECKING(for ada-include)
4691 CF_WITH_PATH(ada-include,
4692    [  --with-ada-include=DIR  Ada includes are in DIR],
4693    ADA_INCLUDE,
4694    PREFIX/share/ada/adainclude,
4695    [$]prefix/share/ada/adainclude)
4696 AC_SUBST(ADA_INCLUDE)
4697 AC_MSG_RESULT($ADA_INCLUDE)
4698 ])dnl
4699 dnl ---------------------------------------------------------------------------
4700 dnl CF_WITH_ADA_LIBNAME version: 1 updated: 2019/09/07 18:59:41
4701 dnl -------------------
4702 dnl CF_WITH_ADA_LIBNAME
4703 dnl -------------------
4704 dnl Command-line option to specify how to name the resulting Ada library.
4705 dnl $1 = default value
4706 AC_DEFUN([CF_WITH_ADA_LIBNAME],[
4707 AC_MSG_CHECKING(for ada-libname)
4708 AC_ARG_WITH(ada-libname,
4709    [  --with-ada-libname=XXX  override default Ada library-name],
4710    ADA_LIBNAME=[$]withval,
4711    ADA_LIBNAME=$1)
4712 case "x$ADA_LIBNAME" in
4713 (x|xyes|xno)
4714         ADA_LIBNAME=$1
4715         ;;
4716 esac
4717 AC_SUBST(ADA_LIBNAME)
4718 AC_MSG_RESULT($ADA_LIBNAME)
4719 ])dnl
4720 dnl ---------------------------------------------------------------------------
4721 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
4722 dnl -------------------
4723 dnl Command-line option to specify where Ada objects will install.
4724 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
4725 AC_MSG_CHECKING(for ada-objects)
4726 CF_WITH_PATH(ada-objects,
4727    [  --with-ada-objects=DIR  Ada objects are in DIR],
4728    ADA_OBJECTS,
4729    PREFIX/lib/ada/adalib,
4730    [$]prefix/lib/ada/adalib)
4731 AC_SUBST(ADA_OBJECTS)
4732 AC_MSG_RESULT($ADA_OBJECTS)
4733 ])dnl
4734 dnl ---------------------------------------------------------------------------
4735 dnl CF_WITH_ADA_SHAREDLIB version: 5 updated: 2018/07/21 19:10:35
4736 dnl ---------------------
4737 dnl Command-line option to specify if an Ada95 shared-library should be built,
4738 dnl and optionally what its soname should be.
4739 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
4740 AC_REQUIRE([CF_GNAT_PROJECTS])
4741 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
4742 AC_ARG_WITH(ada-sharedlib,
4743         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
4744         [with_ada_sharedlib=$withval],
4745         [with_ada_sharedlib=no])
4746 AC_MSG_RESULT($with_ada_sharedlib)
4747
4748 if test "x$with_ada_sharedlib" != xno
4749 then
4750         if test "x$cf_gnat_projects" != xyes
4751         then
4752                 AC_MSG_WARN(disabling shared-library since GNAT projects are not supported)
4753                 with_ada_sharedlib=no
4754         fi
4755 fi
4756
4757 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
4758 MAKE_ADA_SHAREDLIB="#"
4759
4760 if test "x$with_ada_sharedlib" != xno
4761 then
4762         MAKE_ADA_SHAREDLIB=
4763         if test "x$with_ada_sharedlib" != xyes
4764         then
4765                 ADA_SHAREDLIB="$with_ada_sharedlib"
4766         fi
4767 fi
4768
4769 AC_SUBST(ADA_SHAREDLIB)
4770 AC_SUBST(MAKE_ADA_SHAREDLIB)
4771 ])dnl
4772 dnl ---------------------------------------------------------------------------
4773 dnl CF_WITH_CURSES_DIR version: 4 updated: 2021/01/02 19:22:58
4774 dnl ------------------
4775 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
4776 dnl libraries.
4777 AC_DEFUN([CF_WITH_CURSES_DIR],[
4778
4779 AC_MSG_CHECKING(for specific curses-directory)
4780 AC_ARG_WITH(curses-dir,
4781         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
4782         [cf_cv_curses_dir=$withval],
4783         [cf_cv_curses_dir=no])
4784 AC_MSG_RESULT($cf_cv_curses_dir)
4785
4786 if test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no"
4787 then
4788         CF_PATH_SYNTAX(withval)
4789         if test -d "$cf_cv_curses_dir"
4790         then
4791                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
4792                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
4793         fi
4794 fi
4795 ])dnl
4796 dnl ---------------------------------------------------------------------------
4797 dnl CF_WITH_LIB_PREFIX version: 2 updated: 2021/01/01 16:53:59
4798 dnl ------------------
4799 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
4800 dnl "lib" prefix, e.g., because it used the dll naming convention.
4801 dnl
4802 dnl $1 = variable to set
4803 AC_DEFUN([CF_WITH_LIB_PREFIX],
4804 [
4805 AC_MSG_CHECKING(if you want to have a library-prefix)
4806 AC_ARG_WITH(lib-prefix,
4807         [  --with-lib-prefix       override library-prefix],
4808         [with_lib_prefix=$withval],
4809         [with_lib_prefix=auto])
4810 AC_MSG_RESULT($with_lib_prefix)
4811
4812 if test "$with_lib_prefix" = auto
4813 then
4814         CF_LIB_PREFIX($1)
4815 elif test "$with_lib_prefix" = no
4816 then
4817         LIB_PREFIX=
4818 else
4819         LIB_PREFIX=$with_lib_prefix
4820 fi
4821 ])dnl
4822 dnl ---------------------------------------------------------------------------
4823 dnl CF_WITH_PATH version: 12 updated: 2021/09/04 06:35:04
4824 dnl ------------
4825 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
4826 dnl defaulting to yes/no.
4827 dnl
4828 dnl $1 = option name
4829 dnl $2 = help-text
4830 dnl $3 = environment variable to set
4831 dnl $4 = default value, shown in the help-message, must be a constant
4832 dnl $5 = default value, if it is an expression & cannot be in the help-message
4833 dnl
4834 AC_DEFUN([CF_WITH_PATH],
4835 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
4836 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
4837 if ifelse([$5],,true,[test -n "$5"]) ; then
4838 CF_PATH_SYNTAX(withval)
4839 fi
4840 eval $3="$withval"
4841 AC_SUBST($3)dnl
4842 ])dnl
4843 dnl ---------------------------------------------------------------------------
4844 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 21 updated: 2023/01/22 13:37:42
4845 dnl -------------------------
4846 dnl Allow the choice of the pkg-config library directory to be overridden.
4847 dnl
4848 dnl pkg-config uses a search-list built from these colon-separated lists of
4849 dnl directories:
4850 dnl a) $PKG_CONFIG_PATH (tested first, added if set)
4851 dnl b) $PKG_CONFIG_LIBDIR (tested second, added if set)
4852 dnl c) builtin-list (added if $PKG_CONFIG_LIBDIR is not set)
4853 dnl
4854 dnl pkgconf (used with some systems such as FreeBSD in place of pkg-config)
4855 dnl optionally ignores $PKG_CONFIG_LIBDIR.  Very old versions of pkg-config,
4856 dnl e.g., Solaris 10 also do not recognize $PKG_CONFIG_LIBDIR.
4857 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
4858
4859 case "$PKG_CONFIG" in
4860 (no|none|yes)
4861         AC_MSG_CHECKING(for pkg-config library directory)
4862         ;;
4863 (*)
4864         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
4865         ;;
4866 esac
4867
4868 # if $PKG_CONFIG_LIBDIR is set, try to use that
4869 if test -n "$PKG_CONFIG_PATH"; then
4870         cf_search_path=`echo "$PKG_CONFIG_PATH" | sed -e 's/:/ /g' -e 's,^[[    ]]*,,' -e 's,[[         ]]*$,,'`
4871 elif test -n "$PKG_CONFIG_LIBDIR"; then
4872         cf_search_path=`echo "$PKG_CONFIG_LIBDIR" | sed -e 's/:/ /g' -e 's,^[[  ]]*,,' -e 's,[[         ]]*$,,'`
4873 else
4874         cf_search_path=auto
4875 fi
4876
4877 # if the option is used, let that override.  otherwise default to "libdir"
4878 AC_ARG_WITH(pkg-config-libdir,
4879         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
4880         [cf_search_path=$withval],
4881         [test "x$PKG_CONFIG" != xnone && test -z "$cf_search_path" && cf_search_path=libdir])
4882
4883 case "x$cf_search_path" in
4884 (xlibdir)
4885         PKG_CONFIG_LIBDIR='${libdir}/pkgconfig'
4886         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
4887         cf_search_path=
4888         ;;
4889 (x)
4890         ;;
4891 (x/*\ *)
4892         PKG_CONFIG_LIBDIR=
4893         ;;
4894 (x/*)
4895         PKG_CONFIG_LIBDIR="$cf_search_path"
4896         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
4897         cf_search_path=
4898         ;;
4899 (xyes|xauto)
4900         AC_MSG_RESULT(auto)
4901         cf_search_path=
4902         # Look for the library directory using the same prefix as the executable
4903         AC_MSG_CHECKING(for search-list)
4904         if test "x$PKG_CONFIG" != xnone
4905         then
4906                 # works for pkg-config since version 0.24 (2009)
4907                 # works for pkgconf since version 0.8.3 (2012)
4908                 for cf_pkg_program in \
4909                         `echo "$PKG_CONFIG" | sed -e 's,^.*/,,'` \
4910                         pkg-config \
4911                         pkgconf
4912                 do
4913                         cf_search_path=`"$PKG_CONFIG" --variable=pc_path "$cf_pkg_program" 2>/dev/null | tr : ' '`
4914                         test -n "$cf_search_path" && break
4915                 done
4916
4917                 # works for pkg-config since import in 2005 of original 2001 HP code.
4918                 test -z "$cf_search_path" && \
4919                 cf_search_path=`
4920                 "$PKG_CONFIG" --debug --exists no-such-package 2>&1 | $AWK "\
4921 /^Scanning directory (#[1-9][0-9]* )?'.*'$/{ \
4922         sub(\"^[[^']]*'\",\"\"); \
4923         sub(\"'.*\",\"\"); \
4924         printf \" %s\", \\[$]0; } \
4925 { next; } \
4926 "`
4927         fi
4928
4929         AC_MSG_RESULT($cf_search_path)
4930         ;;
4931 (*)
4932         AC_MSG_ERROR(Unexpected option value: $cf_search_path)
4933         ;;
4934 esac
4935
4936 if test -n "$cf_search_path"
4937 then
4938         AC_MSG_CHECKING(for first directory)
4939         cf_pkg_config_path=none
4940         for cf_config in $cf_search_path
4941         do
4942                 if test -d "$cf_config"
4943                 then
4944                         cf_pkg_config_path=$cf_config
4945                         break
4946                 fi
4947         done
4948         AC_MSG_RESULT($cf_pkg_config_path)
4949
4950         if test "x$cf_pkg_config_path" != xnone ; then
4951                 # limit this to the first directory found
4952                 PKG_CONFIG_LIBDIR="$cf_pkg_config_path"
4953         fi
4954
4955         if test -z "$PKG_CONFIG_LIBDIR" && test -n "$cf_search_path"
4956         then
4957                 AC_MSG_CHECKING(for workaround)
4958                 if test "$prefix" = "NONE" ; then
4959                         cf_prefix="$ac_default_prefix"
4960                 else
4961                         cf_prefix="$prefix"
4962                 fi
4963                 eval cf_libdir=$libdir
4964                 cf_libdir=`echo "$cf_libdir" | sed -e "s,^NONE,$cf_prefix,"`
4965                 cf_backup=
4966                 for cf_config in $cf_search_path
4967                 do
4968                         case $cf_config in
4969                         $cf_libdir/pkgconfig)
4970                                 PKG_CONFIG_LIBDIR=$cf_libdir/pkgconfig
4971                                 break
4972                                 ;;
4973                         *)
4974                                 test -z "$cf_backup" && cf_backup=$cf_config
4975                                 ;;
4976                         esac
4977                 done
4978                 test -z "$PKG_CONFIG_LIBDIR" && PKG_CONFIG_LIBDIR=$cf_backup
4979                 AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
4980         fi
4981 fi
4982
4983 AC_SUBST(PKG_CONFIG_LIBDIR)
4984 ])dnl
4985 dnl ---------------------------------------------------------------------------
4986 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
4987 dnl ---------------
4988 dnl Check for POSIX thread library.
4989 AC_DEFUN([CF_WITH_PTHREAD],
4990 [
4991 AC_MSG_CHECKING(if you want to link with the pthread library)
4992 AC_ARG_WITH(pthread,
4993         [  --with-pthread          use POSIX thread library],
4994         [with_pthread=$withval],
4995         [with_pthread=no])
4996 AC_MSG_RESULT($with_pthread)
4997
4998 if test "$with_pthread" != no ; then
4999         AC_CHECK_HEADER(pthread.h,[
5000         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
5001
5002         for cf_lib_pthread in pthread c_r
5003         do
5004             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
5005             cf_save_LIBS="$LIBS"
5006             CF_ADD_LIB($cf_lib_pthread)
5007             AC_TRY_LINK([
5008 #include <pthread.h>
5009 ],[
5010                 int rc = pthread_create(0,0,0,0);
5011                 int r2 = pthread_mutexattr_settype(0, 0);
5012 ],[with_pthread=yes],[with_pthread=no])
5013             LIBS="$cf_save_LIBS"
5014             AC_MSG_RESULT($with_pthread)
5015             test "$with_pthread" = yes && break
5016         done
5017
5018         if test "$with_pthread" = yes ; then
5019             CF_ADD_LIB($cf_lib_pthread)
5020             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
5021         else
5022             AC_MSG_ERROR(Cannot link with pthread library)
5023         fi
5024         ])
5025 fi
5026 ])
5027 dnl ---------------------------------------------------------------------------
5028 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
5029 dnl ---------------
5030 dnl For testing, override the derived host system-type which is used to decide
5031 dnl things such as the linker commands used to build shared libraries.  This is
5032 dnl normally chosen automatically based on the type of system which you are
5033 dnl building on.  We use it for testing the configure script.
5034 dnl
5035 dnl This is different from the --host option: it is used only for testing parts
5036 dnl of the configure script which would not be reachable with --host since that
5037 dnl relies on the build environment being real, rather than mocked up.
5038 AC_DEFUN([CF_WITH_SYSTYPE],[
5039 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
5040 AC_ARG_WITH(system-type,
5041         [  --with-system-type=XXX  test: override derived host system-type],
5042 [AC_MSG_WARN(overriding system type to $withval)
5043         cf_cv_system_name=$withval
5044         host_os=$withval
5045 ])
5046 ])dnl
5047 dnl ---------------------------------------------------------------------------
5048 dnl CF_XOPEN_SOURCE version: 66 updated: 2023/04/03 04:19:37
5049 dnl ---------------
5050 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
5051 dnl or adapt to the vendor's definitions to get equivalent functionality,
5052 dnl without losing the common non-POSIX features.
5053 dnl
5054 dnl Parameters:
5055 dnl     $1 is the nominal value for _XOPEN_SOURCE
5056 dnl     $2 is the nominal value for _POSIX_C_SOURCE
5057 dnl
5058 dnl The default case prefers _XOPEN_SOURCE over _POSIX_C_SOURCE if the
5059 dnl implementation predefines it, because X/Open and most implementations agree
5060 dnl that the latter is a legacy or "aligned" value.
5061 dnl
5062 dnl Because _XOPEN_SOURCE is preferred, if defining _POSIX_C_SOURCE turns
5063 dnl that off, then refrain from setting _POSIX_C_SOURCE explicitly.
5064 dnl
5065 dnl References:
5066 dnl https://pubs.opengroup.org/onlinepubs/007904975/functions/xsh_chap02_02.html
5067 dnl https://docs.oracle.com/cd/E19253-01/816-5175/standards-5/index.html
5068 dnl https://www.gnu.org/software/libc/manual/html_node/Feature-Test-Macros.html
5069 AC_DEFUN([CF_XOPEN_SOURCE],[
5070 AC_REQUIRE([AC_CANONICAL_HOST])
5071 AC_REQUIRE([CF_POSIX_VISIBLE])
5072
5073 if test "$cf_cv_posix_visible" = no; then
5074
5075 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
5076 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
5077 cf_xopen_source=
5078
5079 case "$host_os" in
5080 (aix[[4-7]]*)
5081         cf_xopen_source="-D_ALL_SOURCE"
5082         ;;
5083 (darwin[[0-8]].*)
5084         cf_xopen_source="-D_APPLE_C_SOURCE"
5085         ;;
5086 (darwin*)
5087         cf_xopen_source="-D_DARWIN_C_SOURCE"
5088         cf_XOPEN_SOURCE=
5089         ;;
5090 (freebsd*|dragonfly*|midnightbsd*)
5091         # 5.x headers associate
5092         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
5093         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
5094         cf_POSIX_C_SOURCE=200112L
5095         cf_XOPEN_SOURCE=600
5096         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
5097         ;;
5098 (hpux11*)
5099         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
5100         ;;
5101 (hpux*)
5102         cf_xopen_source="-D_HPUX_SOURCE"
5103         ;;
5104 (irix[[56]].*)
5105         cf_xopen_source="-D_SGI_SOURCE"
5106         cf_XOPEN_SOURCE=
5107         ;;
5108 (linux*gnu|linux*gnuabi64|linux*gnuabin32|linux*gnueabi|linux*gnueabihf|linux*gnux32|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin|msys|mingw*)
5109         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
5110         ;;
5111 (minix*)
5112         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
5113         ;;
5114 (mirbsd*)
5115         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
5116         cf_XOPEN_SOURCE=
5117         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
5118         ;;
5119 (netbsd*)
5120         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
5121         ;;
5122 (openbsd[[6-9]]*)
5123         # OpenBSD 6.x has broken locale support, both compile-time and runtime.
5124         # see https://www.mail-archive.com/bugs@openbsd.org/msg13200.html
5125         # Abusing the conformance level is a workaround.
5126         AC_MSG_WARN(this system does not provide usable locale support)
5127         cf_xopen_source="-D_BSD_SOURCE"
5128         cf_XOPEN_SOURCE=700
5129         ;;
5130 (openbsd[[4-5]]*)
5131         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
5132         cf_xopen_source="-D_BSD_SOURCE"
5133         cf_XOPEN_SOURCE=600
5134         ;;
5135 (openbsd*)
5136         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
5137         ;;
5138 (osf[[45]]*)
5139         cf_xopen_source="-D_OSF_SOURCE"
5140         ;;
5141 (nto-qnx*)
5142         cf_xopen_source="-D_QNX_SOURCE"
5143         ;;
5144 (sco*)
5145         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
5146         ;;
5147 (solaris2.*)
5148         cf_xopen_source="-D__EXTENSIONS__"
5149         cf_cv_xopen_source=broken
5150         ;;
5151 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
5152         cf_XOPEN_SOURCE=
5153         cf_POSIX_C_SOURCE=
5154         ;;
5155 (*)
5156         CF_TRY_XOPEN_SOURCE
5157         cf_save_xopen_cppflags="$CPPFLAGS"
5158         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
5159         # Some of these niche implementations use copy/paste, double-check...
5160         if test "$cf_cv_xopen_source" = no ; then
5161                 CF_VERBOSE(checking if _POSIX_C_SOURCE interferes with _XOPEN_SOURCE)
5162                 AC_TRY_COMPILE(CF__XOPEN_SOURCE_HEAD,CF__XOPEN_SOURCE_BODY,,[
5163                         AC_MSG_WARN(_POSIX_C_SOURCE definition is not usable)
5164                         CPPFLAGS="$cf_save_xopen_cppflags"])
5165         fi
5166         ;;
5167 esac
5168
5169 if test -n "$cf_xopen_source" ; then
5170         CF_APPEND_CFLAGS($cf_xopen_source,true)
5171 fi
5172
5173 dnl In anything but the default case, we may have system-specific setting
5174 dnl which is still not guaranteed to provide all of the entrypoints that
5175 dnl _XOPEN_SOURCE would yield.
5176 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
5177         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
5178         AC_TRY_COMPILE([#include <stdlib.h>],[
5179 #ifndef _XOPEN_SOURCE
5180 #error _XOPEN_SOURCE is not defined
5181 #endif],
5182         [cf_XOPEN_SOURCE_set=yes],
5183         [cf_XOPEN_SOURCE_set=no])
5184         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
5185         if test "$cf_XOPEN_SOURCE_set" = yes
5186         then
5187                 AC_TRY_COMPILE([#include <stdlib.h>],[
5188 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
5189 #error (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
5190 #endif],
5191                 [cf_XOPEN_SOURCE_set_ok=yes],
5192                 [cf_XOPEN_SOURCE_set_ok=no])
5193                 if test "$cf_XOPEN_SOURCE_set_ok" = no
5194                 then
5195                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
5196                 fi
5197         else
5198                 CF_TRY_XOPEN_SOURCE
5199         fi
5200 fi
5201 fi # cf_cv_posix_visible
5202 ])
5203 dnl ---------------------------------------------------------------------------
5204 dnl CF__SED_TRIMBLANKS version: 1 updated: 2021/01/02 09:31:20
5205 dnl ------------------
5206 dnl Trim something using sed, then trim extra whitespace
5207 dnl $1 = extra parameters, e.g., in CF_STRIP_G_OPT
5208 define([CF__SED_TRIMBLANKS],[sed ifelse($1,,,[$1] )-e 's%[[     ]]% %g' -e 's% [[ ]]*% %g' -e 's%^ %%' -e 's% [$]%%'])dnl
5209 dnl ---------------------------------------------------------------------------
5210 dnl CF__XOPEN_SOURCE_BODY version: 2 updated: 2023/02/18 17:41:25
5211 dnl ---------------------
5212 dnl body of test when test-compiling for _XOPEN_SOURCE check
5213 define([CF__XOPEN_SOURCE_BODY],
5214 [
5215 #ifndef _XOPEN_SOURCE
5216 #error _XOPEN_SOURCE is not defined
5217 #endif
5218 ])
5219 dnl ---------------------------------------------------------------------------
5220 dnl CF__XOPEN_SOURCE_HEAD version: 2 updated: 2023/02/18 17:41:25
5221 dnl ---------------------
5222 dnl headers to include when test-compiling for _XOPEN_SOURCE check
5223 define([CF__XOPEN_SOURCE_HEAD],
5224 [
5225 $ac_includes_default
5226 ])