aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2011,2012 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.609 2012/03/17 16:08:47 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 3 updated: 2002/10/27 23:21:42
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54     [AC_TRY_LINK([#include <langinfo.h>],
  55       [char* cs = nl_langinfo(CODESET);],
  56       am_cv_langinfo_codeset=yes,
  57       am_cv_langinfo_codeset=no)
  58     ])
  59   if test $am_cv_langinfo_codeset = yes; then
  60     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62   fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ACVERSION_CHECK version: 2 updated: 2011/05/08 11:22:03
  66 dnl ------------------
  67 dnl Conditionally generate script according to whether we're using a given autoconf.
  68 dnl
  69 dnl $1 = version to compare against
  70 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  71 dnl $3 = code to use if AC_ACVERSION is older than $1.
  72 define(CF_ACVERSION_CHECK,
  73 [
  74 ifdef([m4_version_compare],
  75 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  76 [CF_ACVERSION_COMPARE(
  77 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  78 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  79 dnl ---------------------------------------------------------------------------
  80 dnl CF_ACVERSION_COMPARE version: 2 updated: 2011/04/14 20:56:50
  81 dnl --------------------
  82 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  83 dnl                      MAJOR2, MINOR2, TERNARY2,
  84 dnl                      PRINTABLE2, not FOUND, FOUND)
  85 define(CF_ACVERSION_COMPARE,
  86 [ifelse(builtin([eval], [$2 < $5]), 1,
  87 [ifelse([$8], , ,[$8])],
  88 [ifelse([$9], , ,[$9])])])dnl
  89 dnl ---------------------------------------------------------------------------
  90 dnl CF_ADA_INCLUDE_DIRS version: 6 updated: 2010/02/26 19:52:07
  91 dnl -------------------
  92 dnl Construct the list of include-options for the C programs in the Ada95
  93 dnl binding.
  94 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  95 [
  96 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  97 if test "$srcdir" != "."; then
  98         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  99 fi
 100 if test "$GCC" != yes; then
 101         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 102 elif test "$includedir" != "/usr/include"; then
 103         if test "$includedir" = '${prefix}/include' ; then
 104                 if test $prefix != /usr ; then
 105                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 106                 fi
 107         else
 108                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 109         fi
 110 fi
 111 AC_SUBST(ACPPFLAGS)
 112 ])dnl
 113 dnl ---------------------------------------------------------------------------
 114 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 115 dnl ---------------
 116 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 117 AC_DEFUN([CF_ADD_ADAFLAGS],[
 118         ADAFLAGS="$ADAFLAGS $1"
 119         AC_SUBST(ADAFLAGS)
 120 ])dnl
 121 dnl ---------------------------------------------------------------------------
 122 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
 123 dnl -------------
 124 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 125 dnl The second parameter if given makes this macro verbose.
 126 dnl
 127 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 128 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 129 dnl confused by the quotes (which require backslashes to keep them usable).
 130 AC_DEFUN([CF_ADD_CFLAGS],
 131 [
 132 cf_fix_cppflags=no
 133 cf_new_cflags=
 134 cf_new_cppflags=
 135 cf_new_extra_cppflags=
 136
 137 for cf_add_cflags in $1
 138 do
 139 case $cf_fix_cppflags in
 140 no)
 141         case $cf_add_cflags in #(vi
 142         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
 143                 case $cf_add_cflags in
 144                 -D*)
 145                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 146
 147                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 148                                 && test -z "${cf_tst_cflags}" \
 149                                 && cf_fix_cppflags=yes
 150
 151                         if test $cf_fix_cppflags = yes ; then
 152                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 153                                 continue
 154                         elif test "${cf_tst_cflags}" = "\"'" ; then
 155                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 156                                 continue
 157                         fi
 158                         ;;
 159                 esac
 160                 case "$CPPFLAGS" in
 161                 *$cf_add_cflags) #(vi
 162                         ;;
 163                 *) #(vi
 164                         case $cf_add_cflags in #(vi
 165                         -D*)
 166                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 167                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 168                                 ;;
 169                         esac
 170                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 171                         ;;
 172                 esac
 173                 ;;
 174         *)
 175                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 176                 ;;
 177         esac
 178         ;;
 179 yes)
 180         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 181
 182         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 183
 184         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 185                 && test -z "${cf_tst_cflags}" \
 186                 && cf_fix_cppflags=no
 187         ;;
 188 esac
 189 done
 190
 191 if test -n "$cf_new_cflags" ; then
 192         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 193         CFLAGS="$CFLAGS $cf_new_cflags"
 194 fi
 195
 196 if test -n "$cf_new_cppflags" ; then
 197         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 198         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 199 fi
 200
 201 if test -n "$cf_new_extra_cppflags" ; then
 202         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 203         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 204 fi
 205
 206 AC_SUBST(EXTRA_CPPFLAGS)
 207
 208 ])dnl
 209 dnl ---------------------------------------------------------------------------
 210 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 211 dnl -------------
 212 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 213 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 214 dnl but old versions (and some misinstalled ones) need that.  To make things
 215 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 216 dnl the include-path).
 217 AC_DEFUN([CF_ADD_INCDIR],
 218 [
 219 if test -n "$1" ; then
 220   for cf_add_incdir in $1
 221   do
 222         while test $cf_add_incdir != /usr/include
 223         do
 224           if test -d $cf_add_incdir
 225           then
 226                 cf_have_incdir=no
 227                 if test -n "$CFLAGS$CPPFLAGS" ; then
 228                   # a loop is needed to ensure we can add subdirs of existing dirs
 229                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 230                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 231                           cf_have_incdir=yes; break
 232                         fi
 233                   done
 234                 fi
 235
 236                 if test "$cf_have_incdir" = no ; then
 237                   if test "$cf_add_incdir" = /usr/local/include ; then
 238                         if test "$GCC" = yes
 239                         then
 240                           cf_save_CPPFLAGS=$CPPFLAGS
 241                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 242                           AC_TRY_COMPILE([#include <stdio.h>],
 243                                   [printf("Hello")],
 244                                   [],
 245                                   [cf_have_incdir=yes])
 246                           CPPFLAGS=$cf_save_CPPFLAGS
 247                         fi
 248                   fi
 249                 fi
 250
 251                 if test "$cf_have_incdir" = no ; then
 252                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 253                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 254
 255                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 256                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 257                   cf_add_incdir="$cf_top_incdir"
 258                 else
 259                   break
 260                 fi
 261           fi
 262         done
 263   done
 264 fi
 265 ])dnl
 266 dnl ---------------------------------------------------------------------------
 267 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 268 dnl ----------
 269 dnl Add a library, used to enforce consistency.
 270 dnl
 271 dnl $1 = library to add, without the "-l"
 272 dnl $2 = variable to update (default $LIBS)
 273 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 274 dnl ---------------------------------------------------------------------------
 275 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 276 dnl -------------
 277 dnl     Adds to the library-path
 278 dnl
 279 dnl     Some machines have trouble with multiple -L options.
 280 dnl
 281 dnl $1 is the (list of) directory(s) to add
 282 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 283 dnl
 284 AC_DEFUN([CF_ADD_LIBDIR],
 285 [
 286 if test -n "$1" ; then
 287   for cf_add_libdir in $1
 288   do
 289     if test $cf_add_libdir = /usr/lib ; then
 290       :
 291     elif test -d $cf_add_libdir
 292     then
 293       cf_have_libdir=no
 294       if test -n "$LDFLAGS$LIBS" ; then
 295         # a loop is needed to ensure we can add subdirs of existing dirs
 296         for cf_test_libdir in $LDFLAGS $LIBS ; do
 297           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 298             cf_have_libdir=yes; break
 299           fi
 300         done
 301       fi
 302       if test "$cf_have_libdir" = no ; then
 303         CF_VERBOSE(adding $cf_add_libdir to library-path)
 304         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 305       fi
 306     fi
 307   done
 308 fi
 309 ])dnl
 310 dnl ---------------------------------------------------------------------------
 311 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 312 dnl -----------
 313 dnl Add one or more libraries, used to enforce consistency.
 314 dnl
 315 dnl $1 = libraries to add, with the "-l", etc.
 316 dnl $2 = variable to update (default $LIBS)
 317 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 318 dnl ---------------------------------------------------------------------------
 319 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
 320 dnl ------------------
 321 dnl Append to a search-list for a nonstandard header/lib-file
 322 dnl     $1 = the variable to return as result
 323 dnl     $2 = the package name
 324 dnl     $3 = the subdirectory, e.g., bin, include or lib
 325 dnl $4 = the directory under which we will test for subdirectories
 326 dnl $5 = a directory that we do not want $4 to match
 327 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 328 [
 329 test "$4" != "$5" && \
 330 test -d "$4" && \
 331 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
 332         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 333         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 334         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 335         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 336         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 337         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 338 }
 339 ])dnl
 340 dnl ---------------------------------------------------------------------------
 341 dnl CF_ANSI_CC_CHECK version: 11 updated: 2011/07/01 19:47:45
 342 dnl ----------------
 343 dnl This was originally adapted from the macros 'fp_PROG_CC_STDC' and
 344 dnl 'fp_C_PROTOTYPES' in the sharutils 4.2 distribution.
 345 AC_DEFUN([CF_ANSI_CC_CHECK],
 346 [
 347 # This should have been defined by AC_PROG_CC
 348 : ${CC:=cc}
 349
 350 # Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 351 # into CC.  This will not help with broken scripts that wrap the compiler with
 352 # options, but eliminates a more common category of user confusion.
 353 AC_MSG_CHECKING(\$CC variable)
 354 case "$CC" in #(vi
 355 *[[\ \  ]]-[[IUD]]*)
 356         AC_MSG_RESULT(broken)
 357         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 358         # humor him...
 359         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 360         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 361         CF_ADD_CFLAGS($cf_flags)
 362         ;;
 363 *)
 364         AC_MSG_RESULT(ok)
 365         ;;
 366 esac
 367
 368 AC_CACHE_CHECK(for ${CC:-cc} option to accept ANSI C, cf_cv_ansi_cc,[
 369 cf_cv_ansi_cc=no
 370 cf_save_CFLAGS="$CFLAGS"
 371 cf_save_CPPFLAGS="$CPPFLAGS"
 372 # Don't try gcc -ansi; that turns off useful extensions and
 373 # breaks some systems' header files.
 374 # AIX                   -qlanglvl=ansi
 375 # Ultrix and OSF/1      -std1
 376 # HP-UX                 -Aa -D_HPUX_SOURCE
 377 # SVR4                  -Xc
 378 # UnixWare 1.2          (cannot use -Xc, since ANSI/POSIX clashes)
 379 for cf_arg in "-DCC_HAS_PROTOS" \
 380         "" \
 381         -qlanglvl=ansi \
 382         -std1 \
 383         -Ae \
 384         "-Aa -D_HPUX_SOURCE" \
 385         -Xc
 386 do
 387         CF_ADD_CFLAGS($cf_arg)
 388         AC_TRY_COMPILE(
 389 [
 390 #ifndef CC_HAS_PROTOS
 391 #if !defined(__STDC__) || (__STDC__ != 1)
 392 choke me
 393 #endif
 394 #endif
 395 ],[
 396         int test (int i, double x);
 397         struct s1 {int (*f) (int a);};
 398         struct s2 {int (*f) (double a);};],
 399         [cf_cv_ansi_cc="$cf_arg"; break])
 400 done
 401 CFLAGS="$cf_save_CFLAGS"
 402 CPPFLAGS="$cf_save_CPPFLAGS"
 403 ])
 404
 405 if test "$cf_cv_ansi_cc" != "no"; then
 406 if test ".$cf_cv_ansi_cc" != ".-DCC_HAS_PROTOS"; then
 407         CF_ADD_CFLAGS($cf_cv_ansi_cc)
 408 else
 409         AC_DEFINE(CC_HAS_PROTOS)
 410 fi
 411 fi
 412 ])dnl
 413 dnl ---------------------------------------------------------------------------
 414 dnl CF_ANSI_CC_REQD version: 4 updated: 2008/03/23 14:48:54
 415 dnl ---------------
 416 dnl For programs that must use an ANSI compiler, obtain compiler options that
 417 dnl will make it recognize prototypes.  We'll do preprocessor checks in other
 418 dnl macros, since tools such as unproto can fake prototypes, but only part of
 419 dnl the preprocessor.
 420 AC_DEFUN([CF_ANSI_CC_REQD],
 421 [AC_REQUIRE([CF_ANSI_CC_CHECK])
 422 if test "$cf_cv_ansi_cc" = "no"; then
 423         AC_MSG_ERROR(
 424 [Your compiler does not appear to recognize prototypes.
 425 You have the following choices:
 426         a. adjust your compiler options
 427         b. get an up-to-date compiler
 428         c. use a wrapper such as unproto])
 429 fi
 430 ])dnl
 431 dnl ---------------------------------------------------------------------------
 432 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 433 dnl --------------
 434 dnl Allow user to disable a normally-on option.
 435 AC_DEFUN([CF_ARG_DISABLE],
 436 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 437 dnl ---------------------------------------------------------------------------
 438 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 439 dnl -------------
 440 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 441 dnl values.
 442 dnl
 443 dnl Parameters:
 444 dnl $1 = option name
 445 dnl $2 = help-string
 446 dnl $3 = action to perform if option is not default
 447 dnl $4 = action if perform if option is default
 448 dnl $5 = default option value (either 'yes' or 'no')
 449 AC_DEFUN([CF_ARG_OPTION],
 450 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 451   if test "$enableval" != "$5" ; then
 452 ifelse([$3],,[    :]dnl
 453 ,[    $3]) ifelse([$4],,,[
 454   else
 455     $4])
 456   fi],[enableval=$5 ifelse([$4],,,[
 457   $4
 458 ])dnl
 459   ])])dnl
 460 dnl ---------------------------------------------------------------------------
 461 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 462 dnl -----------
 463 dnl Check for suitable "ar" (archiver) options for updating an archive.
 464 AC_DEFUN([CF_AR_FLAGS],[
 465 AC_REQUIRE([CF_PROG_AR])
 466
 467 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 468         cf_cv_ar_flags=unknown
 469         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 470         do
 471
 472                 # check if $ARFLAGS already contains this choice
 473                 if test "x$ARFLAGS" != "x" ; then
 474                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 475                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 476                                 cf_cv_ar_flags=
 477                                 break
 478                         fi
 479                 fi
 480
 481                 rm -f conftest.$ac_cv_objext
 482                 rm -f conftest.a
 483
 484                 cat >conftest.$ac_ext <<EOF
 485 #line __oline__ "configure"
 486 int     testdata[[3]] = { 123, 456, 789 };
 487 EOF
 488                 if AC_TRY_EVAL(ac_compile) ; then
 489                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 490                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 491                         if test -f conftest.a ; then
 492                                 cf_cv_ar_flags=$cf_ar_flags
 493                                 break
 494                         fi
 495                 else
 496                         CF_VERBOSE(cannot compile test-program)
 497                         break
 498                 fi
 499         done
 500         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 501 ])
 502
 503 if test -n "$ARFLAGS" ; then
 504         if test -n "$cf_cv_ar_flags" ; then
 505                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 506         fi
 507 else
 508         ARFLAGS=$cf_cv_ar_flags
 509 fi
 510
 511 AC_SUBST(ARFLAGS)
 512 ])
 513 dnl ---------------------------------------------------------------------------
 514 dnl CF_AWK_BIG_PRINTF version: 4 updated: 2011/10/30 17:09:50
 515 dnl -----------------
 516 dnl Check if awk can handle big strings using printf.  Some older versions of
 517 dnl awk choke on large strings passed via "%s".
 518 dnl
 519 dnl $1 = desired string size
 520 dnl $2 = variable to set with result
 521 AC_DEFUN([CF_AWK_BIG_PRINTF],
 522 [
 523         case x$AWK in #(vi
 524         x)
 525                 eval $2=no
 526                 ;;
 527         *) #(vi
 528                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 529                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 530                         eval $2=yes
 531                 else
 532                         eval $2=no
 533                 fi
 534                 ;;
 535         esac
 536 ])dnl
 537 dnl ---------------------------------------------------------------------------
 538 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 539 dnl ------------
 540 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 541 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 542 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 543 dnl
 544 dnl Treat the configuration-variable specially here, since we're directly
 545 dnl substituting its value (i.e., 1/0).
 546 dnl
 547 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 548 AC_DEFUN([CF_BOOL_DECL],
 549 [
 550 AC_MSG_CHECKING(if we should include stdbool.h)
 551
 552 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 553         AC_TRY_COMPILE([],[bool foo = false],
 554                 [cf_cv_header_stdbool_h=0],
 555                 [AC_TRY_COMPILE([
 556 #ifndef __BEOS__
 557 #include <stdbool.h>
 558 #endif
 559 ],[bool foo = false],
 560                         [cf_cv_header_stdbool_h=1],
 561                         [cf_cv_header_stdbool_h=0])])])
 562
 563 if test "$cf_cv_header_stdbool_h" = 1
 564 then    AC_MSG_RESULT(yes)
 565 else    AC_MSG_RESULT(no)
 566 fi
 567
 568 AC_MSG_CHECKING([for builtin bool type])
 569
 570 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 571         AC_TRY_COMPILE([
 572 #include <stdio.h>
 573 #include <sys/types.h>
 574 ],[bool x = false],
 575                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 576                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 577         ])
 578
 579 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 580 then    AC_MSG_RESULT(yes)
 581 else    AC_MSG_RESULT(no)
 582 fi
 583 ])dnl
 584 dnl ---------------------------------------------------------------------------
 585 dnl CF_BOOL_SIZE version: 12 updated: 2006/12/16 12:33:30
 586 dnl ------------
 587 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 588 dnl Don't bother looking for bool.h, since it's been deprecated.
 589 dnl
 590 dnl If the current compiler is C rather than C++, we get the bool definition
 591 dnl from <stdbool.h>.
 592 AC_DEFUN([CF_BOOL_SIZE],
 593 [
 594 AC_MSG_CHECKING([for size of bool])
 595 AC_CACHE_VAL(cf_cv_type_of_bool,[
 596         rm -f cf_test.out
 597         AC_TRY_RUN([
 598 #include <stdlib.h>
 599 #include <stdio.h>
 600
 601 #if defined(__cplusplus)
 602
 603 #ifdef HAVE_GXX_BUILTIN_H
 604 #include <g++/builtin.h>
 605 #elif HAVE_GPP_BUILTIN_H
 606 #include <gpp/builtin.h>
 607 #elif HAVE_BUILTIN_H
 608 #include <builtin.h>
 609 #endif
 610
 611 #else
 612
 613 #if $cf_cv_header_stdbool_h
 614 #include <stdbool.h>
 615 #endif
 616
 617 #endif
 618
 619 main()
 620 {
 621         FILE *fp = fopen("cf_test.out", "w");
 622         if (fp != 0) {
 623                 bool x = true;
 624                 if ((bool)(-x) >= 0)
 625                         fputs("unsigned ", fp);
 626                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 627                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 628                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 629                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 630                 fclose(fp);
 631         }
 632         ${cf_cv_main_return:-return}(0);
 633 }
 634                 ],
 635                 [cf_cv_type_of_bool=`cat cf_test.out`
 636                  if test -z "$cf_cv_type_of_bool"; then
 637                    cf_cv_type_of_bool=unknown
 638                  fi],
 639                 [cf_cv_type_of_bool=unknown],
 640                 [cf_cv_type_of_bool=unknown])
 641         ])
 642         rm -f cf_test.out
 643 AC_MSG_RESULT($cf_cv_type_of_bool)
 644 if test "$cf_cv_type_of_bool" = unknown ; then
 645         case .$NCURSES_BOOL in #(vi
 646         .auto|.) NCURSES_BOOL=unsigned;;
 647         esac
 648         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 649         cf_cv_type_of_bool=$NCURSES_BOOL
 650 fi
 651 ])dnl
 652 dnl ---------------------------------------------------------------------------
 653 dnl CF_BUILD_CC version: 6 updated: 2006/10/14 15:23:15
 654 dnl -----------
 655 dnl If we're cross-compiling, allow the user to override the tools and their
 656 dnl options.  The configure script is oriented toward identifying the host
 657 dnl compiler, etc., but we need a build compiler to generate parts of the
 658 dnl source.
 659 dnl
 660 dnl $1 = default for $CPPFLAGS
 661 dnl $2 = default for $LIBS
 662 AC_DEFUN([CF_BUILD_CC],[
 663 AC_REQUIRE([CF_PROG_EXT])
 664 if test "$cross_compiling" = yes ; then
 665
 666         # defaults that we might want to override
 667         : ${BUILD_CFLAGS:=''}
 668         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 669         : ${BUILD_LDFLAGS:=''}
 670         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 671         : ${BUILD_EXEEXT:='$x'}
 672         : ${BUILD_OBJEXT:='o'}
 673
 674         AC_ARG_WITH(build-cc,
 675                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 676                 [BUILD_CC="$withval"],
 677                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 678         AC_MSG_CHECKING(for native build C compiler)
 679         AC_MSG_RESULT($BUILD_CC)
 680
 681         AC_MSG_CHECKING(for native build C preprocessor)
 682         AC_ARG_WITH(build-cpp,
 683                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 684                 [BUILD_CPP="$withval"],
 685                 [BUILD_CPP='${BUILD_CC} -E'])
 686         AC_MSG_RESULT($BUILD_CPP)
 687
 688         AC_MSG_CHECKING(for native build C flags)
 689         AC_ARG_WITH(build-cflags,
 690                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 691                 [BUILD_CFLAGS="$withval"])
 692         AC_MSG_RESULT($BUILD_CFLAGS)
 693
 694         AC_MSG_CHECKING(for native build C preprocessor-flags)
 695         AC_ARG_WITH(build-cppflags,
 696                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 697                 [BUILD_CPPFLAGS="$withval"])
 698         AC_MSG_RESULT($BUILD_CPPFLAGS)
 699
 700         AC_MSG_CHECKING(for native build linker-flags)
 701         AC_ARG_WITH(build-ldflags,
 702                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 703                 [BUILD_LDFLAGS="$withval"])
 704         AC_MSG_RESULT($BUILD_LDFLAGS)
 705
 706         AC_MSG_CHECKING(for native build linker-libraries)
 707         AC_ARG_WITH(build-libs,
 708                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 709                 [BUILD_LIBS="$withval"])
 710         AC_MSG_RESULT($BUILD_LIBS)
 711
 712         # this assumes we're on Unix.
 713         BUILD_EXEEXT=
 714         BUILD_OBJEXT=o
 715
 716         : ${BUILD_CC:='${CC}'}
 717
 718         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 719                 AC_MSG_ERROR([Cross-build requires two compilers.
 720 Use --with-build-cc to specify the native compiler.])
 721         fi
 722
 723 else
 724         : ${BUILD_CC:='${CC}'}
 725         : ${BUILD_CPP:='${CPP}'}
 726         : ${BUILD_CFLAGS:='${CFLAGS}'}
 727         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 728         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 729         : ${BUILD_LIBS:='${LIBS}'}
 730         : ${BUILD_EXEEXT:='$x'}
 731         : ${BUILD_OBJEXT:='o'}
 732 fi
 733
 734 AC_SUBST(BUILD_CC)
 735 AC_SUBST(BUILD_CPP)
 736 AC_SUBST(BUILD_CFLAGS)
 737 AC_SUBST(BUILD_CPPFLAGS)
 738 AC_SUBST(BUILD_LDFLAGS)
 739 AC_SUBST(BUILD_LIBS)
 740 AC_SUBST(BUILD_EXEEXT)
 741 AC_SUBST(BUILD_OBJEXT)
 742 ])dnl
 743 dnl ---------------------------------------------------------------------------
 744 dnl CF_CFG_DEFAULTS version: 8 updated: 2011/06/04 20:09:13
 745 dnl ---------------
 746 dnl Determine the default configuration into which we'll install ncurses.  This
 747 dnl can be overridden by the user's command-line options.  There's two items to
 748 dnl look for:
 749 dnl     1. the prefix (e.g., /usr)
 750 dnl     2. the header files (e.g., /usr/include/ncurses)
 751 dnl We'll look for a previous installation of ncurses and use the same defaults.
 752 dnl
 753 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 754 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 755 dnl programs from a vendor's.
 756 AC_DEFUN([CF_CFG_DEFAULTS],
 757 [
 758 AC_MSG_CHECKING(for prefix)
 759 if test "x$prefix" = "xNONE" ; then
 760         case "$cf_cv_system_name" in
 761                 # non-vendor systems don't have a conflict
 762         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|k*bsd*-gnu)
 763                 prefix=/usr
 764                 ;;
 765         *)      prefix=$ac_default_prefix
 766                 ;;
 767         esac
 768 fi
 769 AC_MSG_RESULT($prefix)
 770
 771 if test "x$prefix" = "xNONE" ; then
 772 AC_MSG_CHECKING(for default include-directory)
 773 test -n "$verbose" && echo 1>&AC_FD_MSG
 774 for cf_symbol in \
 775         $includedir \
 776         $includedir/ncurses \
 777         $prefix/include \
 778         $prefix/include/ncurses \
 779         /usr/local/include \
 780         /usr/local/include/ncurses \
 781         /usr/include \
 782         /usr/include/ncurses
 783 do
 784         cf_dir=`eval echo $cf_symbol`
 785         if test -f $cf_dir/curses.h ; then
 786         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 787                 includedir="$cf_symbol"
 788                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 789                 break
 790         fi
 791         fi
 792         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 793 done
 794 AC_MSG_RESULT($includedir)
 795 fi
 796 ])dnl
 797 dnl ---------------------------------------------------------------------------
 798 dnl CF_CGETENT version: 4 updated: 2011/08/07 14:54:41
 799 dnl ----------
 800 dnl Check if the terminal-capability database functions are available.  If not,
 801 dnl ncurses has a much-reduced version.
 802 AC_DEFUN([CF_CGETENT],[
 803 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 804 AC_TRY_LINK([
 805 #include <stdlib.h>],[
 806         char temp[128];
 807         char *buf = temp;
 808         char *db_array = temp;
 809         cgetent(&buf, &db_array, "vt100");
 810         cgetcap(buf, "tc", '=');
 811         cgetmatch(buf, "tc");
 812         ],
 813         [cf_cv_cgetent=yes],
 814         [cf_cv_cgetent=no])
 815 ])
 816
 817 if test "$cf_cv_cgetent" = yes
 818 then
 819         AC_DEFINE(HAVE_BSD_CGETENT)
 820 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 821 AC_TRY_LINK([
 822 #include <stdlib.h>],[
 823         char temp[128];
 824         char *buf = temp;
 825 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 826         const char *db_array = temp;
 827         cgetent(&buf, &db_array, "vt100");
 828 #endif
 829         cgetcap(buf, "tc", '=');
 830         cgetmatch(buf, "tc");
 831         ],
 832         [cf_cv_cgetent_const=yes],
 833         [cf_cv_cgetent_const=no])
 834 ])
 835         if test "$cf_cv_cgetent_const" = yes
 836         then
 837                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const)
 838         fi
 839 fi
 840 ])dnl
 841 dnl ---------------------------------------------------------------------------
 842 dnl CF_CHECK_CACHE version: 11 updated: 2008/03/23 14:45:59
 843 dnl --------------
 844 dnl Check if we're accidentally using a cache from a different machine.
 845 dnl Derive the system name, as a check for reusing the autoconf cache.
 846 dnl
 847 dnl If we've packaged config.guess and config.sub, run that (since it does a
 848 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 849 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 850 dnl which is useful in cross-compiles.
 851 dnl
 852 dnl Note: we would use $ac_config_sub, but that is one of the places where
 853 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 854 AC_DEFUN([CF_CHECK_CACHE],
 855 [
 856 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 857         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 858         system_name="$host_os"
 859 else
 860         system_name="`(uname -s -r) 2>/dev/null`"
 861         if test -z "$system_name" ; then
 862                 system_name="`(hostname) 2>/dev/null`"
 863         fi
 864 fi
 865 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name")
 866 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 867
 868 test -z "$system_name" && system_name="$cf_cv_system_name"
 869 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 870
 871 if test ".$system_name" != ".$cf_cv_system_name" ; then
 872         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 873         AC_MSG_ERROR("Please remove config.cache and try again.")
 874 fi
 875 ])dnl
 876 dnl ---------------------------------------------------------------------------
 877 dnl CF_CHECK_ERRNO version: 11 updated: 2010/05/26 05:38:42
 878 dnl --------------
 879 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 880 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 881 dnl ourselves.
 882 dnl
 883 dnl $1 = the name to check
 884 dnl $2 = the assumed type
 885 AC_DEFUN([CF_CHECK_ERRNO],
 886 [
 887 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 888     AC_TRY_COMPILE([
 889 #ifdef HAVE_STDLIB_H
 890 #include <stdlib.h>
 891 #endif
 892 #include <stdio.h>
 893 #include <sys/types.h>
 894 #include <errno.h> ],
 895     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 896     [cf_cv_dcl_$1=yes],
 897     [cf_cv_dcl_$1=no])
 898 ])
 899
 900 if test "$cf_cv_dcl_$1" = no ; then
 901     CF_UPPER(cf_result,decl_$1)
 902     AC_DEFINE_UNQUOTED($cf_result)
 903 fi
 904
 905 # It's possible (for near-UNIX clones) that the data doesn't exist
 906 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 907 ])dnl
 908 dnl ---------------------------------------------------------------------------
 909 dnl CF_CHECK_EXTERN_DATA version: 3 updated: 2001/12/30 18:03:23
 910 dnl --------------------
 911 dnl Check for existence of external data in the current set of libraries.  If
 912 dnl we can modify it, it's real enough.
 913 dnl $1 = the name to check
 914 dnl $2 = its type
 915 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 916 [
 917 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 918     AC_TRY_LINK([
 919 #undef $1
 920 extern $2 $1;
 921 ],
 922     [$1 = 2],
 923     [cf_cv_have_$1=yes],
 924     [cf_cv_have_$1=no])
 925 ])
 926
 927 if test "$cf_cv_have_$1" = yes ; then
 928     CF_UPPER(cf_result,have_$1)
 929     AC_DEFINE_UNQUOTED($cf_result)
 930 fi
 931
 932 ])dnl
 933 dnl ---------------------------------------------------------------------------
 934 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 935 dnl -------------------
 936 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 937 dnl is not "weak" - warn about this because it can create problems linking
 938 dnl applications with ncurses.
 939 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 940 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 941
 942 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 943 cf_cv_check_gpm_wgetch=unknown
 944 if test "$cross_compiling" != yes ; then
 945
 946 cat >conftest.$ac_ext <<CF_EOF
 947 #include <gpm.h>
 948 int main()
 949 {
 950         Gpm_Wgetch();
 951         ${cf_cv_main_return:-return}(0);
 952 }
 953 CF_EOF
 954
 955         cf_save_LIBS="$LIBS"
 956         # This only works if we can look at the symbol table.  If a shared
 957         # library is stripped for install, we cannot use that.  So we're forced
 958         # to rely on the static library, noting that some packagers may not
 959         # include it.
 960         LIBS="-static -lgpm -dynamic $LIBS"
 961         if AC_TRY_EVAL(ac_compile) ; then
 962                 if AC_TRY_EVAL(ac_link) ; then
 963                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 964                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 965                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 966                 fi
 967         fi
 968         rm -rf conftest*
 969         LIBS="$cf_save_LIBS"
 970 fi
 971 ])
 972
 973 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 974         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 975 fi
 976 ])])dnl
 977 dnl ---------------------------------------------------------------------------
 978 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
 979 dnl ----------------
 980 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
 981 AC_DEFUN([CF_CHECK_WCHAR_H],[
 982 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
 983 AC_TRY_COMPILE(
 984 [
 985 #include <stdlib.h>
 986 #include <wchar.h>
 987 ],[
 988         wint_t foo = 0;
 989         int bar = iswpunct(foo)],
 990         [cf_cv_wchar_h_okay=yes],
 991         [cf_cv_wchar_h_okay=no])])
 992
 993 if test $cf_cv_wchar_h_okay = no
 994 then
 995         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 996 fi
 997 ])dnl
 998 dnl ---------------------------------------------------------------------------
 999 dnl CF_CPP_PARAM_INIT version: 5 updated: 2011/12/03 16:54:03
1000 dnl -----------------
1001 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1002 dnl is a late feature for the standard and is not in some recent compilers
1003 dnl (1999/9/11).
1004 AC_DEFUN([CF_CPP_PARAM_INIT],
1005 [
1006 if test -n "$CXX"; then
1007 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1008         AC_LANG_SAVE
1009         AC_LANG_CPLUSPLUS
1010         AC_TRY_RUN([
1011 class TEST {
1012 private:
1013         int value;
1014 public:
1015         TEST(int x = 1);
1016         ~TEST();
1017 };
1018
1019 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1020 {
1021         value = x;
1022 }
1023 int main() { }
1024 ],
1025         [cf_cv_cpp_param_init=yes],
1026         [cf_cv_cpp_param_init=no],
1027         [cf_cv_cpp_param_init=unknown])
1028         AC_LANG_RESTORE
1029 ])
1030 fi
1031 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT)
1032 ])dnl
1033 dnl ---------------------------------------------------------------------------
1034 dnl CF_CPP_STATIC_CAST version: 1 updated: 2005/07/23 16:52:43
1035 dnl ------------------
1036 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1037 dnl not be supported in g++ before 3.0
1038 AC_DEFUN([CF_CPP_STATIC_CAST],
1039 [
1040 if test -n "$CXX"; then
1041
1042 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1043         AC_LANG_SAVE
1044         AC_LANG_CPLUSPLUS
1045
1046         AC_TRY_COMPILE([
1047 class NCursesPanel
1048 {
1049 public:
1050   NCursesPanel(int nlines,
1051                int ncols,
1052                int begin_y = 0,
1053                int begin_x = 0)
1054   {
1055   }
1056
1057   ~NCursesPanel();
1058 };
1059
1060 template<class T> class NCursesUserPanel : public NCursesPanel
1061 {
1062 public:
1063   NCursesUserPanel (int nlines,
1064                     int ncols,
1065                     int begin_y = 0,
1066                     int begin_x = 0,
1067                     const T* p_UserData = static_cast<T*>(0))
1068     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1069   {
1070   };
1071   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1072   {
1073   };
1074
1075   virtual ~NCursesUserPanel() {};
1076 };
1077 ],[
1078         const char* p_UserData = static_cast<char*>(0)],
1079         [cf_cv_cpp_static_cast=yes],
1080         [cf_cv_cpp_static_cast=no])
1081
1082         AC_LANG_RESTORE
1083 ])
1084
1085 fi
1086
1087 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST)
1088 ])dnl
1089 dnl ---------------------------------------------------------------------------
1090 dnl CF_CXX_AR_FLAGS version: 1 updated: 2011/10/29 08:35:34
1091 dnl ---------------
1092 dnl Setup special archiver flags for given compilers.
1093 AC_DEFUN([CF_CXX_AR_FLAGS],[
1094         CXX_AR='$(AR)'
1095         CXX_ARFLAGS='$(ARFLAGS)'
1096         case $cf_cv_system_name in #(vi
1097         irix*) #(vi
1098             if test "$GXX" != yes ; then
1099                 CXX_AR='$(CXX)'
1100                 CXX_ARFLAGS='-ar -o'
1101             fi
1102             ;;
1103         sco3.2v5*) #(vi
1104             CXXLDFLAGS="-u main"
1105             ;;
1106         solaris2*)
1107             if test "$GXX" != yes ; then
1108                 CXX_AR='$(CXX)'
1109                 CXX_ARFLAGS='-xar -o'
1110             fi
1111             ;;
1112         esac
1113         AC_SUBST(CXXLDFLAGS)
1114         AC_SUBST(CXX_AR)
1115         AC_SUBST(CXX_ARFLAGS)
1116 ])dnl
1117 dnl ---------------------------------------------------------------------------
1118 dnl CF_CXX_IOSTREAM_NAMESPACE version: 1 updated: 2011/10/29 08:35:34
1119 dnl -------------------------
1120 dnl For c++, check if iostream uses "std::" namespace.
1121 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1122 AC_CHECK_HEADERS(iostream)
1123 if test x"$ac_cv_header_iostream" = xyes ; then
1124         AC_MSG_CHECKING(if iostream uses std-namespace)
1125         AC_TRY_COMPILE([
1126 #include <iostream>
1127 using std::endl;
1128 using std::cerr;],[
1129 cerr << "testing" << endl;
1130 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1131         AC_MSG_RESULT($cf_iostream_namespace)
1132         if test "$cf_iostream_namespace" = yes ; then
1133                 AC_DEFINE(IOSTREAM_NAMESPACE)
1134         fi
1135 fi
1136 ])dnl
1137 dnl ---------------------------------------------------------------------------
1138 dnl CF_C_INLINE version: 3 updated: 2010/05/01 15:14:41
1139 dnl -----------
1140 dnl Check if the C compiler supports "inline".
1141 dnl $1 is the name of a shell variable to set if inline is supported
1142 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1143 AC_DEFUN([CF_C_INLINE],[
1144 AC_C_INLINE
1145 $1=
1146 if test "$ac_cv_c_inline" != no ; then
1147   $1=inline
1148   if test "$INTEL_COMPILER" = yes
1149   then
1150     :
1151   elif test "$GCC" = yes
1152   then
1153     AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1154       cf_save_CFLAGS=$CFLAGS
1155       CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1156       AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1157       [${cf_cv_main_return:-return} foo()],
1158       [cf_cv_gcc_inline=yes],
1159       [cf_cv_gcc_inline=no])
1160       CFLAGS=$cf_save_CFLAGS
1161     ])
1162     if test "$cf_cv_gcc_inline" = yes ; then
1163         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1164     fi
1165   fi
1166 fi
1167 AC_SUBST($1)
1168 ])dnl
1169 dnl ---------------------------------------------------------------------------
1170 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1171 dnl ----------
1172 dnl "dirname" is not portable, so we fake it with a shell script.
1173 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1174 dnl ---------------------------------------------------------------------------
1175 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1176 dnl ---------------
1177 AC_DEFUN([CF_DIRS_TO_MAKE],
1178 [
1179 DIRS_TO_MAKE="lib"
1180 for cf_item in $cf_list_models
1181 do
1182         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1183         for cf_item2 in $DIRS_TO_MAKE
1184         do
1185                 test $cf_item2 = $cf_subdir && break
1186         done
1187         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1188 done
1189 for cf_dir in $DIRS_TO_MAKE
1190 do
1191         test ! -d $cf_dir && mkdir $cf_dir
1192 done
1193 AC_SUBST(DIRS_TO_MAKE)
1194 ])dnl
1195 dnl ---------------------------------------------------------------------------
1196 dnl CF_DISABLE_ECHO version: 11 updated: 2009/12/13 13:16:57
1197 dnl ---------------
1198 dnl You can always use "make -n" to see the actual options, but it's hard to
1199 dnl pick out/analyze warning messages when the compile-line is long.
1200 dnl
1201 dnl Sets:
1202 dnl     ECHO_LT - symbol to control if libtool is verbose
1203 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1204 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1205 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1206 dnl     ECHO_CC - symbol to put before any "cc" line
1207 dnl
1208 AC_DEFUN([CF_DISABLE_ECHO],[
1209 AC_MSG_CHECKING(if you want to see long compiling messages)
1210 CF_ARG_DISABLE(echo,
1211         [  --disable-echo          display "compiling" commands],
1212         [
1213     ECHO_LT='--silent'
1214     ECHO_LD='@echo linking [$]@;'
1215     RULE_CC='@echo compiling [$]<'
1216     SHOW_CC='@echo compiling [$]@'
1217     ECHO_CC='@'
1218 ],[
1219     ECHO_LT=''
1220     ECHO_LD=''
1221     RULE_CC=''
1222     SHOW_CC=''
1223     ECHO_CC=''
1224 ])
1225 AC_MSG_RESULT($enableval)
1226 AC_SUBST(ECHO_LT)
1227 AC_SUBST(ECHO_LD)
1228 AC_SUBST(RULE_CC)
1229 AC_SUBST(SHOW_CC)
1230 AC_SUBST(ECHO_CC)
1231 ])dnl
1232 dnl ---------------------------------------------------------------------------
1233 dnl CF_DISABLE_LEAKS version: 6 updated: 2010/07/23 04:14:32
1234 dnl ----------------
1235 dnl Combine no-leak checks with the libraries or tools that are used for the
1236 dnl checks.
1237 AC_DEFUN([CF_DISABLE_LEAKS],[
1238
1239 AC_REQUIRE([CF_WITH_DMALLOC])
1240 AC_REQUIRE([CF_WITH_DBMALLOC])
1241 AC_REQUIRE([CF_WITH_VALGRIND])
1242
1243 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1244 AC_ARG_ENABLE(leaks,
1245         [  --disable-leaks         test: free permanent memory, analyze leaks],
1246         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1247         : ${with_no_leaks:=no})
1248 AC_MSG_RESULT($with_no_leaks)
1249
1250 if test "$with_no_leaks" = yes ; then
1251         AC_DEFINE(NO_LEAKS)
1252         AC_DEFINE(YY_NO_LEAKS)
1253 fi
1254 ])dnl
1255 dnl ---------------------------------------------------------------------------
1256 dnl CF_DISABLE_LIBTOOL_VERSION version: 1 updated: 2010/05/15 15:45:59
1257 dnl --------------------------
1258 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1259 dnl the older "-version-info" feature.  The newer feature allows us to use
1260 dnl version numbering on shared libraries which make them compatible with
1261 dnl various systems.
1262 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1263 [
1264 AC_MSG_CHECKING(if libtool -version-number should be used)
1265 CF_ARG_DISABLE(libtool-version,
1266         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1267         [cf_libtool_version=no],
1268         [cf_libtool_version=yes])
1269 AC_MSG_RESULT($cf_libtool_version)
1270
1271 if test "$cf_libtool_version" = yes ; then
1272         LIBTOOL_VERSION="-version-number"
1273 else
1274         LIBTOOL_VERSION="-version-info"
1275 fi
1276
1277 AC_SUBST(LIBTOOL_VERSION)
1278 ])dnl
1279 dnl ---------------------------------------------------------------------------
1280 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1281 dnl ---------------------
1282 dnl The rpath-hack makes it simpler to build programs, particularly with the
1283 dnl *BSD ports which may have essential libraries in unusual places.  But it
1284 dnl can interfere with building an executable for the base system.  Use this
1285 dnl option in that case.
1286 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1287 [
1288 AC_MSG_CHECKING(if rpath-hack should be disabled)
1289 CF_ARG_DISABLE(rpath-hack,
1290         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1291         [cf_disable_rpath_hack=yes],
1292         [cf_disable_rpath_hack=no])
1293 AC_MSG_RESULT($cf_disable_rpath_hack)
1294 if test "$cf_disable_rpath_hack" = no ; then
1295         CF_RPATH_HACK
1296 fi
1297 ])
1298 dnl ---------------------------------------------------------------------------
1299 dnl CF_ENABLE_PC_FILES version: 7 updated: 2011/12/10 18:58:47
1300 dnl ------------------
1301 dnl This is the "--enable-pc-files" option, which is available if there is a
1302 dnl pkg-config configuration on the local machine.
1303 AC_DEFUN([CF_ENABLE_PC_FILES],[
1304 AC_REQUIRE([CF_PKG_CONFIG])
1305 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1306
1307 if test "$PKG_CONFIG" != none ; then
1308         if test -n "$PKG_CONFIG_LIBDIR" && test -d "$PKG_CONFIG_LIBDIR" ; then
1309                 AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1310                 AC_ARG_ENABLE(pc-files,
1311                         [  --enable-pc-files       generate and install .pc files for pkg-config],
1312                         [enable_pc_files=$enableval],
1313                         [enable_pc_files=no])
1314                 AC_MSG_RESULT($enable_pc_files)
1315         elif test -z "$PKG_CONFIG_LIBDIR" || test "$PKG_CONFIG_LIBDIR" != no; then
1316                 enable_pc_files=no
1317                 AC_MSG_WARN(did not find $PKG_CONFIG library)
1318         fi
1319 else
1320         enable_pc_files=no
1321 fi
1322 ])dnl
1323 dnl ---------------------------------------------------------------------------
1324 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1325 dnl ---------------
1326 dnl Check if the rpath option should be used, setting cache variable
1327 dnl cf_cv_enable_rpath if so.
1328 AC_DEFUN([CF_ENABLE_RPATH],
1329 [
1330 AC_MSG_CHECKING(if rpath option should be used)
1331 AC_ARG_ENABLE(rpath,
1332 [  --enable-rpath          use rpath option when generating shared libraries],
1333 [cf_cv_enable_rpath=$enableval],
1334 [cf_cv_enable_rpath=no])
1335 AC_MSG_RESULT($cf_cv_enable_rpath)
1336 ])dnl
1337 dnl ---------------------------------------------------------------------------
1338 dnl CF_ENABLE_STRING_HACKS version: 1 updated: 2012/02/25 06:33:21
1339 dnl ----------------------
1340 dnl On a few platforms, the compiler and/or loader nags with untruthful
1341 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1342 dnl and implying that most uses of the recommended alternatives are correct.
1343 dnl
1344 dnl Factually speaking, no one has actually counted the number of uses of these
1345 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1346 dnl instances are meaningless compared to the hundreds of millions of lines of
1347 dnl existing C code.
1348 dnl
1349 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1350 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1351 dnl standard - but evolved through phases, and older implementations are likely
1352 dnl to yield surprising results, as documented in manpages on various systems.
1353 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1354 [
1355 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1356 AC_ARG_ENABLE(string-hacks,
1357         [  --enable-string-hacks  work around bogus compiler/loader warnings],
1358         [with_string_hacks=$enableval],
1359         [with_string_hacks=no])
1360 AC_MSG_RESULT($with_string_hacks)
1361
1362 if test "x$with_string_hacks" = "xyes"; then
1363         AC_DEFINE(USE_STRING_HACKS)
1364         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1365         AC_CHECK_FUNCS( strlcat strlcpy snprintf )
1366 fi
1367 ])dnl
1368 dnl ---------------------------------------------------------------------------
1369 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1370 dnl --------
1371 dnl Check if 'errno' is declared in <errno.h>
1372 AC_DEFUN([CF_ERRNO],
1373 [
1374 CF_CHECK_ERRNO(errno)
1375 ])dnl
1376 dnl ---------------------------------------------------------------------------
1377 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1378 dnl ---------------
1379 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1380 dnl math.h and builtin.h, only for ncurses
1381 AC_DEFUN([CF_ETIP_DEFINES],
1382 [
1383 AC_MSG_CHECKING(for special defines needed for etip.h)
1384 cf_save_CXXFLAGS="$CXXFLAGS"
1385 cf_result="none"
1386
1387 # etip.h includes ncurses.h which includes ncurses_dll.h
1388 # But ncurses_dll.h is generated - fix here.
1389 test -d include || mkdir include
1390 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1391
1392 for cf_math in "" MATH_H
1393 do
1394 for cf_excp in "" MATH_EXCEPTION
1395 do
1396         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1397         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1398         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1399 AC_TRY_COMPILE([
1400 #include <etip.h.in>
1401 ],[],[
1402         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1403         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1404         cf_result="$cf_math $cf_excp"
1405         break 2
1406 ],[])
1407 done
1408 done
1409 AC_MSG_RESULT($cf_result)
1410 CXXFLAGS="$cf_save_CXXFLAGS"
1411 ])
1412 dnl ---------------------------------------------------------------------------
1413 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1414 dnl ---------------
1415 dnl Find a library (specifically the linkage used in the code fragment),
1416 dnl searching for it if it is not already in the library path.
1417 dnl See also CF_ADD_SEARCHPATH.
1418 dnl
1419 dnl Parameters (4-on are optional):
1420 dnl     $1 = headers for library entrypoint
1421 dnl     $2 = code fragment for library entrypoint
1422 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1423 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1424 dnl     $5 = action to perform if not successful
1425 dnl     $6 = module name, if not the same as the library name
1426 dnl     $7 = extra libraries
1427 dnl
1428 dnl Sets these variables:
1429 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1430 dnl     $cf_cv_header_path_$3 - include-directory if needed
1431 dnl     $cf_cv_library_path_$3 - library-directory if needed
1432 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1433 AC_DEFUN([CF_FIND_LINKAGE],[
1434
1435 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1436 # will be set on completion of the AC_TRY_LINK below.
1437 cf_cv_header_path_$3=
1438 cf_cv_library_path_$3=
1439
1440 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1441
1442 cf_save_LIBS="$LIBS"
1443
1444 AC_TRY_LINK([$1],[$2],[
1445         cf_cv_find_linkage_$3=yes
1446         cf_cv_header_path_$3=/usr/include
1447         cf_cv_library_path_$3=/usr/lib
1448 ],[
1449
1450 LIBS="-l$3 $7 $cf_save_LIBS"
1451
1452 AC_TRY_LINK([$1],[$2],[
1453         cf_cv_find_linkage_$3=yes
1454         cf_cv_header_path_$3=/usr/include
1455         cf_cv_library_path_$3=/usr/lib
1456         cf_cv_library_file_$3="-l$3"
1457 ],[
1458         cf_cv_find_linkage_$3=no
1459         LIBS="$cf_save_LIBS"
1460
1461     CF_VERBOSE(find linkage for $3 library)
1462     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1463
1464     cf_save_CPPFLAGS="$CPPFLAGS"
1465     cf_test_CPPFLAGS="$CPPFLAGS"
1466
1467     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1468     for cf_cv_header_path_$3 in $cf_search
1469     do
1470       if test -d $cf_cv_header_path_$3 ; then
1471         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1472         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1473         AC_TRY_COMPILE([$1],[$2],[
1474             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1475             cf_cv_find_linkage_$3=maybe
1476             cf_test_CPPFLAGS="$CPPFLAGS"
1477             break],[
1478             CPPFLAGS="$cf_save_CPPFLAGS"
1479             ])
1480       fi
1481     done
1482
1483     if test "$cf_cv_find_linkage_$3" = maybe ; then
1484
1485       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1486
1487       cf_save_LIBS="$LIBS"
1488       cf_save_LDFLAGS="$LDFLAGS"
1489
1490       ifelse([$6],,,[
1491         CPPFLAGS="$cf_test_CPPFLAGS"
1492         LIBS="-l$3 $7 $cf_save_LIBS"
1493         AC_TRY_LINK([$1],[$2],[
1494             CF_VERBOSE(... found $3 library in system)
1495             cf_cv_find_linkage_$3=yes])
1496             CPPFLAGS="$cf_save_CPPFLAGS"
1497             LIBS="$cf_save_LIBS"
1498             ])
1499
1500       if test "$cf_cv_find_linkage_$3" != yes ; then
1501         CF_LIBRARY_PATH(cf_search,$3)
1502         for cf_cv_library_path_$3 in $cf_search
1503         do
1504           if test -d $cf_cv_library_path_$3 ; then
1505             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1506             CPPFLAGS="$cf_test_CPPFLAGS"
1507             LIBS="-l$3 $7 $cf_save_LIBS"
1508             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1509             AC_TRY_LINK([$1],[$2],[
1510                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1511                 cf_cv_find_linkage_$3=yes
1512                 cf_cv_library_file_$3="-l$3"
1513                 break],[
1514                 CPPFLAGS="$cf_save_CPPFLAGS"
1515                 LIBS="$cf_save_LIBS"
1516                 LDFLAGS="$cf_save_LDFLAGS"
1517                 ])
1518           fi
1519         done
1520         CPPFLAGS="$cf_save_CPPFLAGS"
1521         LDFLAGS="$cf_save_LDFLAGS"
1522       fi
1523
1524     else
1525       cf_cv_find_linkage_$3=no
1526     fi
1527     ],$7)
1528 ])
1529
1530 LIBS="$cf_save_LIBS"
1531
1532 if test "$cf_cv_find_linkage_$3" = yes ; then
1533 ifelse([$4],,[
1534         CF_ADD_INCDIR($cf_cv_header_path_$3)
1535         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1536         CF_ADD_LIB($3)
1537 ],[$4])
1538 else
1539 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1540 fi
1541 ])dnl
1542 dnl ---------------------------------------------------------------------------
1543 dnl CF_FUNC_DLSYM version: 2 updated: 2010/05/29 16:31:02
1544 dnl -------------
1545 dnl Test for dlsym() and related functions, as well as libdl.
1546 dnl
1547 dnl Sets
1548 dnl     $cf_have_dlsym
1549 dnl     $cf_have_libdl
1550 AC_DEFUN([CF_FUNC_DLSYM],[
1551 cf_have_dlsym=no
1552 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1553
1554 cf_have_libdl=no
1555 AC_CHECK_LIB(dl,dlsym,[
1556         cf_have_dlsym=yes
1557         cf_have_libdl=yes])])
1558
1559 if test "$cf_have_dlsym" = yes ; then
1560         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1561
1562         AC_MSG_CHECKING(whether able to link to dl*() functions)
1563         AC_TRY_LINK([#include <dlfcn.h>],[
1564                 void *obj;
1565                 if ((obj = dlopen("filename", 0)) != 0) {
1566                         if (dlsym(obj, "symbolname") == 0) {
1567                         dlclose(obj);
1568                         }
1569                 }],[
1570                 AC_DEFINE(HAVE_LIBDL)],[
1571                 AC_MSG_ERROR(Cannot link test program for libdl)])
1572         AC_MSG_RESULT(ok)
1573 else
1574         AC_MSG_ERROR(Cannot find dlsym function)
1575 fi
1576 ])
1577 dnl ---------------------------------------------------------------------------
1578 dnl CF_FUNC_MEMMOVE version: 7 updated: 2006/12/16 12:33:30
1579 dnl ---------------
1580 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1581 dnl is found, add our own version of memmove to the list of objects.
1582 AC_DEFUN([CF_FUNC_MEMMOVE],
1583 [
1584 AC_CHECK_FUNC(memmove,,[
1585 AC_CHECK_FUNC(bcopy,[
1586         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1587                 AC_TRY_RUN([
1588 int main() {
1589         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1590         char temp[40];
1591         bcopy(data, temp, sizeof(data));
1592         bcopy(temp+10, temp, 15);
1593         bcopy(temp+5, temp+15, 10);
1594         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1595 }
1596                 ],
1597                 [cf_cv_good_bcopy=yes],
1598                 [cf_cv_good_bcopy=no],
1599                 [cf_cv_good_bcopy=unknown])
1600                 ])
1601         ],[cf_cv_good_bcopy=no])
1602         if test "$cf_cv_good_bcopy" = yes ; then
1603                 AC_DEFINE(USE_OK_BCOPY)
1604         else
1605                 AC_DEFINE(USE_MY_MEMMOVE)
1606         fi
1607 ])])dnl
1608 dnl ---------------------------------------------------------------------------
1609 dnl CF_FUNC_NANOSLEEP version: 3 updated: 2006/12/16 12:33:30
1610 dnl -----------------
1611 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1612 dnl AIX 4.x, provide a non-working version.
1613 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1614 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1615 AC_TRY_RUN([
1616 #include <stdio.h>
1617 #include <errno.h>
1618 #include <time.h>
1619
1620 #ifdef HAVE_SYS_TIME_H
1621 #include <sys/time.h>
1622 #endif
1623
1624 int main() {
1625         struct timespec ts1, ts2;
1626         int code;
1627         ts1.tv_sec  = 0;
1628         ts1.tv_nsec = 750000000;
1629         ts2.tv_sec  = 0;
1630         ts2.tv_nsec = 0;
1631         errno = 0;
1632         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1633         ${cf_cv_main_return:-return}(code != 0);
1634 }
1635 ],
1636         [cf_cv_func_nanosleep=yes],
1637         [cf_cv_func_nanosleep=no],
1638         [cf_cv_func_nanosleep=unknown])])
1639
1640 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP)
1641 ])
1642 dnl ---------------------------------------------------------------------------
1643 dnl CF_FUNC_OPENPTY version: 3 updated: 2010/05/29 16:31:02
1644 dnl ---------------
1645 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1646 dnl "util" library as well.
1647 AC_DEFUN([CF_FUNC_OPENPTY],
1648 [
1649 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1650 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1651     cf_save_LIBS="$LIBS"
1652     test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1653     for cf_header in pty.h libutil.h util.h
1654     do
1655     AC_TRY_LINK([
1656 #include <$cf_header>
1657 ],[
1658     int x = openpty((int *)0, (int *)0, (char *)0,
1659                    (struct termios *)0, (struct winsize *)0);
1660 ],[
1661         cf_cv_func_openpty=$cf_header
1662         break
1663 ],[
1664         cf_cv_func_openpty=no
1665 ])
1666     done
1667     LIBS="$cf_save_LIBS"
1668 ])
1669 ])dnl
1670 dnl ---------------------------------------------------------------------------
1671 dnl CF_FUNC_POLL version: 5 updated: 2012/01/25 17:55:38
1672 dnl ------------
1673 dnl See if the poll function really works.  Some platforms have poll(), but
1674 dnl it does not work for terminals or files.
1675 AC_DEFUN([CF_FUNC_POLL],[
1676 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1677 AC_TRY_RUN([
1678 #include <stdio.h>
1679 #ifdef HAVE_POLL_H
1680 #include <poll.h>
1681 #else
1682 #include <sys/poll.h>
1683 #endif
1684 int main() {
1685         struct pollfd myfds;
1686         int ret;
1687
1688         /* check for Darwin bug with respect to "devices" */
1689         myfds.fd = open("/dev/null", 1);
1690         if (myfds.fd < 0)
1691                 myfds.fd = 0;
1692         myfds.events = POLLIN;
1693         myfds.revents = 0;
1694
1695         ret = poll(&myfds, 1, 100);
1696
1697         if (ret < 0 || (myfds.revents & POLLNVAL)) {
1698                 ret = -1;
1699         } else {
1700
1701                 /* also check with standard input */
1702                 myfds.fd = 0;
1703                 myfds.events = POLLIN;
1704                 myfds.revents = 0;
1705
1706                 ret = poll(&myfds, 1, 100);
1707                 if (ret < 0) {
1708                         ret = 0;
1709                 }
1710         }
1711         ${cf_cv_main_return:-return}(ret != 0);
1712 }],
1713         [cf_cv_working_poll=yes],
1714         [cf_cv_working_poll=no],
1715         [cf_cv_working_poll=unknown])])
1716 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL)
1717 ])dnl
1718 dnl ---------------------------------------------------------------------------
1719 dnl CF_FUNC_TERMIOS version: 2 updated: 2000/07/22 23:37:24
1720 dnl ---------------
1721 dnl Some old/broken variations define tcgetattr() only as a macro in
1722 dnl termio(s).h
1723 AC_DEFUN([CF_FUNC_TERMIOS],[
1724 AC_REQUIRE([CF_STRUCT_TERMIOS])
1725 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1726 AC_TRY_LINK([
1727 #include <sys/types.h>
1728 #ifdef HAVE_UNISTD_H
1729 #include <unistd.h>
1730 #endif
1731 #ifdef HAVE_TERMIOS_H
1732 #include <termios.h>
1733 #define TTY struct termios
1734 #else
1735 #ifdef HAVE_TERMIO_H
1736 #include <termio.h>
1737 #define TTY struct termio
1738 #endif
1739 #endif
1740 ],[
1741 TTY foo;
1742 tcgetattr(1, &foo);],
1743 [cf_cv_have_tcgetattr=yes],
1744 [cf_cv_have_tcgetattr=no])])
1745 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR)
1746 ])dnl
1747 dnl ---------------------------------------------------------------------------
1748 dnl CF_FUNC_VSSCANF version: 3 updated: 2001/12/19 00:50:10
1749 dnl ---------------
1750 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1751 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1752 dnl other functions.
1753 AC_DEFUN([CF_FUNC_VSSCANF],
1754 [
1755 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1756 AC_TRY_LINK([
1757 #include <stdarg.h>
1758 #include <stdio.h>],[
1759         va_list ap;
1760         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1761 AC_TRY_LINK([
1762 #include <stdarg.h>
1763 #include <stdio.h>],[
1764     FILE strbuf;
1765     char *str = "from";
1766
1767     strbuf._flag = _IOREAD;
1768     strbuf._ptr = strbuf._base = (unsigned char *) str;
1769     strbuf._cnt = strlen(str);
1770     strbuf._file = _NFILE;
1771     return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1772 AC_TRY_LINK([
1773 #include <stdarg.h>
1774 #include <stdio.h>],[
1775     FILE strbuf;
1776     char *str = "from";
1777
1778     strbuf._flag = _IOREAD;
1779     strbuf._ptr = strbuf._base = (unsigned char *) str;
1780     strbuf._cnt = strlen(str);
1781     strbuf._file = _NFILE;
1782     return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1783 cf_cv_func_vsscanf=no])])])])
1784
1785 case $cf_cv_func_vsscanf in #(vi
1786 vsscanf) AC_DEFINE(HAVE_VSSCANF);; #(vi
1787 vfscanf) AC_DEFINE(HAVE_VFSCANF);; #(vi
1788 _doscan) AC_DEFINE(HAVE__DOSCAN);;
1789 esac
1790
1791 ])dnl
1792 dnl ---------------------------------------------------------------------------
1793 dnl CF_GCC_ATTRIBUTES version: 14 updated: 2010/10/23 15:52:32
1794 dnl -----------------
1795 dnl Test for availability of useful gcc __attribute__ directives to quiet
1796 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1797 dnl to documentation, unrecognized directives cause older compilers to barf.
1798 AC_DEFUN([CF_GCC_ATTRIBUTES],
1799 [
1800 if test "$GCC" = yes
1801 then
1802 cat > conftest.i <<EOF
1803 #ifndef GCC_PRINTF
1804 #define GCC_PRINTF 0
1805 #endif
1806 #ifndef GCC_SCANF
1807 #define GCC_SCANF 0
1808 #endif
1809 #ifndef GCC_NORETURN
1810 #define GCC_NORETURN /* nothing */
1811 #endif
1812 #ifndef GCC_UNUSED
1813 #define GCC_UNUSED /* nothing */
1814 #endif
1815 EOF
1816 if test "$GCC" = yes
1817 then
1818         AC_CHECKING([for $CC __attribute__ directives])
1819 cat > conftest.$ac_ext <<EOF
1820 #line __oline__ "${as_me:-configure}"
1821 #include "confdefs.h"
1822 #include "conftest.h"
1823 #include "conftest.i"
1824 #if     GCC_PRINTF
1825 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1826 #else
1827 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1828 #endif
1829 #if     GCC_SCANF
1830 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1831 #else
1832 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1833 #endif
1834 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1835 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1836 extern void foo(void) GCC_NORETURN;
1837 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1838 EOF
1839         cf_printf_attribute=no
1840         cf_scanf_attribute=no
1841         for cf_attribute in scanf printf unused noreturn
1842         do
1843                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1844                 cf_directive="__attribute__(($cf_attribute))"
1845                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1846
1847                 case $cf_attribute in #(vi
1848                 printf) #(vi
1849                         cf_printf_attribute=yes
1850                         cat >conftest.h <<EOF
1851 #define GCC_$cf_ATTRIBUTE 1
1852 EOF
1853                         ;;
1854                 scanf) #(vi
1855                         cf_scanf_attribute=yes
1856                         cat >conftest.h <<EOF
1857 #define GCC_$cf_ATTRIBUTE 1
1858 EOF
1859                         ;;
1860                 *) #(vi
1861                         cat >conftest.h <<EOF
1862 #define GCC_$cf_ATTRIBUTE $cf_directive
1863 EOF
1864                         ;;
1865                 esac
1866
1867                 if AC_TRY_EVAL(ac_compile); then
1868                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1869                         cat conftest.h >>confdefs.h
1870                         case $cf_attribute in #(vi
1871                         printf) #(vi
1872                                 if test "$cf_printf_attribute" = no ; then
1873                                         cat >>confdefs.h <<EOF
1874 #define GCC_PRINTFLIKE(fmt,var) /* nothing */
1875 EOF
1876                                 else
1877                                         cat >>confdefs.h <<EOF
1878 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1879 EOF
1880                                 fi
1881                                 ;;
1882                         scanf) #(vi
1883                                 if test "$cf_scanf_attribute" = no ; then
1884                                         cat >>confdefs.h <<EOF
1885 #define GCC_SCANFLIKE(fmt,var) /* nothing */
1886 EOF
1887                                 else
1888                                         cat >>confdefs.h <<EOF
1889 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1890 EOF
1891                                 fi
1892                                 ;;
1893                         esac
1894                 fi
1895         done
1896 else
1897         fgrep define conftest.i >>confdefs.h
1898 fi
1899 rm -rf conftest*
1900 fi
1901 ])dnl
1902 dnl ---------------------------------------------------------------------------
1903 dnl CF_GCC_VERSION version: 5 updated: 2010/04/24 11:02:31
1904 dnl --------------
1905 dnl Find version of gcc
1906 AC_DEFUN([CF_GCC_VERSION],[
1907 AC_REQUIRE([AC_PROG_CC])
1908 GCC_VERSION=none
1909 if test "$GCC" = yes ; then
1910         AC_MSG_CHECKING(version of $CC)
1911         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1912         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1913         AC_MSG_RESULT($GCC_VERSION)
1914 fi
1915 ])dnl
1916 dnl ---------------------------------------------------------------------------
1917 dnl CF_GCC_WARNINGS version: 27 updated: 2010/10/23 15:52:32
1918 dnl ---------------
1919 dnl Check if the compiler supports useful warning options.  There's a few that
1920 dnl we don't use, simply because they're too noisy:
1921 dnl
1922 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1923 dnl     -Wredundant-decls (system headers make this too noisy)
1924 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1925 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1926 dnl             is enabled for ncurses using "--enable-const".
1927 dnl     -pedantic
1928 dnl
1929 dnl Parameter:
1930 dnl     $1 is an optional list of gcc warning flags that a particular
1931 dnl             application might want to use, e.g., "no-unused" for
1932 dnl             -Wno-unused
1933 dnl Special:
1934 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1935 dnl
1936 AC_DEFUN([CF_GCC_WARNINGS],
1937 [
1938 AC_REQUIRE([CF_GCC_VERSION])
1939 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1940
1941 cat > conftest.$ac_ext <<EOF
1942 #line __oline__ "${as_me:-configure}"
1943 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1944 EOF
1945
1946 if test "$INTEL_COMPILER" = yes
1947 then
1948 # The "-wdXXX" options suppress warnings:
1949 # remark #1419: external declaration in primary source file
1950 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1951 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1952 # remark #193: zero used for undefined preprocessing identifier
1953 # remark #593: variable "curs_sb_left_arrow" was set but never used
1954 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1955 # remark #869: parameter "tw" was never referenced
1956 # remark #981: operands are evaluated in unspecified order
1957 # warning #279: controlling expression is constant
1958
1959         AC_CHECKING([for $CC warning options])
1960         cf_save_CFLAGS="$CFLAGS"
1961         EXTRA_CFLAGS="-Wall"
1962         for cf_opt in \
1963                 wd1419 \
1964                 wd1683 \
1965                 wd1684 \
1966                 wd193 \
1967                 wd593 \
1968                 wd279 \
1969                 wd810 \
1970                 wd869 \
1971                 wd981
1972         do
1973                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1974                 if AC_TRY_EVAL(ac_compile); then
1975                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1976                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1977                 fi
1978         done
1979         CFLAGS="$cf_save_CFLAGS"
1980
1981 elif test "$GCC" = yes
1982 then
1983         AC_CHECKING([for $CC warning options])
1984         cf_save_CFLAGS="$CFLAGS"
1985         EXTRA_CFLAGS=
1986         cf_warn_CONST=""
1987         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1988         for cf_opt in W Wall \
1989                 Wbad-function-cast \
1990                 Wcast-align \
1991                 Wcast-qual \
1992                 Winline \
1993                 Wmissing-declarations \
1994                 Wmissing-prototypes \
1995                 Wnested-externs \
1996                 Wpointer-arith \
1997                 Wshadow \
1998                 Wstrict-prototypes \
1999                 Wundef $cf_warn_CONST $1
2000         do
2001                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2002                 if AC_TRY_EVAL(ac_compile); then
2003                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2004                         case $cf_opt in #(vi
2005                         Wcast-qual) #(vi
2006                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2007                                 ;;
2008                         Winline) #(vi
2009                                 case $GCC_VERSION in
2010                                 [[34]].*)
2011                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2012                                         continue;;
2013                                 esac
2014                                 ;;
2015                         esac
2016                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2017                 fi
2018         done
2019         CFLAGS="$cf_save_CFLAGS"
2020 fi
2021 rm -rf conftest*
2022
2023 AC_SUBST(EXTRA_CFLAGS)
2024 ])dnl
2025 dnl ---------------------------------------------------------------------------
2026 dnl CF_GETOPT_HEADER version: 4 updated: 2009/08/31 20:07:52
2027 dnl ----------------
2028 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2029 dnl unistd.h or (nonstandard) in getopt.h
2030 AC_DEFUN([CF_GETOPT_HEADER],
2031 [
2032 AC_HAVE_HEADERS(unistd.h getopt.h)
2033 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2034 cf_cv_getopt_header=none
2035 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2036 do
2037 AC_TRY_COMPILE([
2038 #include <$cf_header>],
2039 [int x = optind; char *y = optarg],
2040 [cf_cv_getopt_header=$cf_header
2041  break])
2042 done
2043 ])
2044 if test $cf_cv_getopt_header != none ; then
2045         AC_DEFINE(HAVE_GETOPT_HEADER)
2046 fi
2047 ])dnl
2048 dnl ---------------------------------------------------------------------------
2049 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
2050 dnl ----------------
2051 AC_DEFUN([CF_GNAT_GENERICS],
2052 [
2053 AC_REQUIRE([CF_GNAT_VERSION])
2054
2055 AC_MSG_CHECKING(if GNAT supports generics)
2056 case $cf_gnat_version in #(vi
2057 3.[[1-9]]*|[[4-9]].*) #(vi
2058         cf_gnat_generics=yes
2059         ;;
2060 *)
2061         cf_gnat_generics=no
2062         ;;
2063 esac
2064 AC_MSG_RESULT($cf_gnat_generics)
2065
2066 if test "$cf_gnat_generics" = yes
2067 then
2068         cf_compile_generics=generics
2069         cf_generic_objects="\${GENOBJS}"
2070 else
2071         cf_compile_generics=
2072         cf_generic_objects=
2073 fi
2074
2075 AC_SUBST(cf_compile_generics)
2076 AC_SUBST(cf_generic_objects)
2077 ])dnl
2078 dnl ---------------------------------------------------------------------------
2079 dnl CF_GNAT_PRAGMA_UNREF version: 1 updated: 2010/06/19 15:22:18
2080 dnl --------------------
2081 dnl Check if the gnat pragma "Unreferenced" works.
2082 AC_DEFUN([CF_GNAT_PRAGMA_UNREF],[
2083 AC_CACHE_CHECK(if GNAT pragma Unreferenced works,cf_cv_pragma_unreferenced,[
2084 CF_GNAT_TRY_LINK([procedure conftest;],
2085 [with Text_IO;
2086 with GNAT.OS_Lib;
2087 procedure conftest is
2088    test : Integer;
2089    pragma Unreferenced (test);
2090 begin
2091    test := 1;
2092    Text_IO.Put ("Hello World");
2093    Text_IO.New_Line;
2094    GNAT.OS_Lib.OS_Exit (0);
2095 end conftest;],
2096         [cf_cv_pragma_unreferenced=yes],
2097         [cf_cv_pragma_unreferenced=no])])
2098
2099 # if the pragma is supported, use it (needed in the Trace code).
2100 if test $cf_cv_pragma_unreferenced = yes ; then
2101         PRAGMA_UNREF=TRUE
2102 else
2103         PRAGMA_UNREF=FALSE
2104 fi
2105 AC_SUBST(PRAGMA_UNREF)
2106 ])dnl
2107 dnl ---------------------------------------------------------------------------
2108 dnl CF_GNAT_PROJECTS version: 2 updated: 2011/03/23 20:24:41
2109 dnl ----------------
2110 dnl GNAT projects are configured with ".gpr" project files.
2111 dnl GNAT libraries are a further development, using the project feature.
2112 AC_DEFUN([CF_GNAT_PROJECTS],
2113 [
2114 AC_REQUIRE([CF_GNAT_VERSION])
2115
2116 cf_gnat_libraries=no
2117 cf_gnat_projects=no
2118
2119 AC_MSG_CHECKING(if GNAT supports project files)
2120 case $cf_gnat_version in #(vi
2121 3.[[0-9]]*) #(vi
2122         ;;
2123 *)
2124         case $cf_cv_system_name in #(vi
2125         cygwin*) #(vi
2126                 ;;
2127         *)
2128                 mkdir conftest.src conftest.bin conftest.lib
2129                 cd conftest.src
2130                 rm -rf conftest* *~conftest*
2131                 cat >>library.gpr <<CF_EOF
2132 project Library is
2133   Kind := External ("LIB_KIND");
2134   for Library_Name use "ConfTest";
2135   for Object_Dir use ".";
2136   for Library_ALI_Dir use External("LIBRARY_DIR");
2137   for Library_Version use External ("SONAME");
2138   for Library_Kind use Kind;
2139   for Library_Dir use External("BUILD_DIR");
2140   Source_Dir := External ("SOURCE_DIR");
2141   for Source_Dirs use (Source_Dir);
2142   package Compiler is
2143      for Default_Switches ("Ada") use
2144        ("-g",
2145         "-O2",
2146         "-gnatafno",
2147         "-gnatVa",   -- All validity checks
2148         "-gnatwa");  -- Activate all optional errors
2149   end Compiler;
2150 end Library;
2151 CF_EOF
2152                 cat >>confpackage.ads <<CF_EOF
2153 package ConfPackage is
2154    procedure conftest;
2155 end ConfPackage;
2156 CF_EOF
2157                 cat >>confpackage.adb <<CF_EOF
2158 with Text_IO;
2159 package body ConfPackage is
2160    procedure conftest is
2161    begin
2162       Text_IO.Put ("Hello World");
2163       Text_IO.New_Line;
2164    end conftest;
2165 end ConfPackage;
2166 CF_EOF
2167                 if ( $cf_ada_make $ADAFLAGS \
2168                                 -Plibrary.gpr \
2169                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2170                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2171                                 -XSOURCE_DIR=`pwd` \
2172                                 -XSONAME=libConfTest.so.1 \
2173                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2174                         cf_gnat_projects=yes
2175                 fi
2176                 cd ..
2177                 if test -f conftest.lib/confpackage.ali
2178                 then
2179                         cf_gnat_libraries=yes
2180                 fi
2181                 rm -rf conftest* *~conftest*
2182                 ;;
2183         esac
2184         ;;
2185 esac
2186 AC_MSG_RESULT($cf_gnat_projects)
2187
2188 if test $cf_gnat_projects = yes
2189 then
2190         AC_MSG_CHECKING(if GNAT supports libraries)
2191         AC_MSG_RESULT($cf_gnat_libraries)
2192 fi
2193
2194 if test "$cf_gnat_projects" = yes
2195 then
2196         USE_OLD_MAKERULES="#"
2197         USE_GNAT_PROJECTS=""
2198 else
2199         USE_OLD_MAKERULES=""
2200         USE_GNAT_PROJECTS="#"
2201 fi
2202
2203 if test "$cf_gnat_libraries" = yes
2204 then
2205         USE_GNAT_LIBRARIES=""
2206 else
2207         USE_GNAT_LIBRARIES="#"
2208 fi
2209
2210 AC_SUBST(USE_OLD_MAKERULES)
2211 AC_SUBST(USE_GNAT_PROJECTS)
2212 AC_SUBST(USE_GNAT_LIBRARIES)
2213 ])dnl
2214 dnl ---------------------------------------------------------------------------
2215 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2216 dnl --------------
2217 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2218 dnl is noted that gnat may compile a tasking unit even for configurations which
2219 dnl fail at runtime.
2220 AC_DEFUN([CF_GNAT_SIGINT],[
2221 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2222 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2223
2224 package ConfTest is
2225
2226    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2227    pragma Unreserve_All_Interrupts;
2228    pragma Warnings (On);
2229
2230    protected Process is
2231       procedure Stop;
2232       function Continue return Boolean;
2233       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2234    private
2235       Done : Boolean := False;
2236    end Process;
2237
2238 end ConfTest;],
2239 [package body ConfTest is
2240    protected body Process is
2241       procedure Stop is
2242       begin
2243          Done := True;
2244       end Stop;
2245       function Continue return Boolean is
2246       begin
2247          return not Done;
2248       end Continue;
2249    end Process;
2250 end ConfTest;],
2251         [cf_cv_gnat_sigint=yes],
2252         [cf_cv_gnat_sigint=no])])
2253
2254 if test $cf_cv_gnat_sigint = yes ; then
2255         USE_GNAT_SIGINT=""
2256 else
2257         USE_GNAT_SIGINT="#"
2258 fi
2259 AC_SUBST(USE_GNAT_SIGINT)
2260 ])dnl
2261 dnl ---------------------------------------------------------------------------
2262 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2263 dnl ----------------
2264 dnl Verify that a test program compiles/links with GNAT.
2265 dnl $cf_ada_make is set to the program that compiles/links
2266 dnl $ADAFLAGS may be set to the GNAT flags.
2267 dnl
2268 dnl $1 is the text of the spec
2269 dnl $2 is the text of the body
2270 dnl $3 is the shell command to execute if successful
2271 dnl $4 is the shell command to execute if not successful
2272 AC_DEFUN([CF_GNAT_TRY_LINK],
2273 [
2274 rm -rf conftest* *~conftest*
2275 cat >>conftest.ads <<CF_EOF
2276 $1
2277 CF_EOF
2278 cat >>conftest.adb <<CF_EOF
2279 $2
2280 CF_EOF
2281 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2282 ifelse($3,,      :,[      $3])
2283 ifelse($4,,,[else
2284    $4])
2285 fi
2286 rm -rf conftest* *~conftest*
2287 ])dnl
2288 dnl ---------------------------------------------------------------------------
2289 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2290 dnl ---------------
2291 dnl Verify that a test program compiles and runs with GNAT
2292 dnl $cf_ada_make is set to the program that compiles/links
2293 dnl $ADAFLAGS may be set to the GNAT flags.
2294 dnl
2295 dnl $1 is the text of the spec
2296 dnl $2 is the text of the body
2297 dnl $3 is the shell command to execute if successful
2298 dnl $4 is the shell command to execute if not successful
2299 AC_DEFUN([CF_GNAT_TRY_RUN],
2300 [
2301 rm -rf conftest* *~conftest*
2302 cat >>conftest.ads <<CF_EOF
2303 $1
2304 CF_EOF
2305 cat >>conftest.adb <<CF_EOF
2306 $2
2307 CF_EOF
2308 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2309    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2310 ifelse($3,,      :,[      $3])
2311 ifelse($4,,,[   else
2312       $4])
2313    fi
2314 ifelse($4,,,[else
2315    $4])
2316 fi
2317 rm -rf conftest* *~conftest*
2318 ])dnl
2319 dnl ---------------------------------------------------------------------------
2320 dnl CF_GNAT_VERSION version: 18 updated: 2012/01/21 19:28:10
2321 dnl ---------------
2322 dnl Verify version of GNAT.
2323 AC_DEFUN([CF_GNAT_VERSION],
2324 [
2325 AC_MSG_CHECKING(for gnat version)
2326 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2327         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2328     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2329 AC_MSG_RESULT($cf_gnat_version)
2330
2331 case $cf_gnat_version in #(vi
2332 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]]) #(vi
2333         cf_cv_prog_gnat_correct=yes
2334         ;;
2335 *)
2336         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2337         cf_cv_prog_gnat_correct=no
2338         ;;
2339 esac
2340 ])
2341 dnl ---------------------------------------------------------------------------
2342 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2343 dnl -------------
2344 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2345 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2346 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2347 dnl since it is interwoven with GNU extensions.
2348 dnl
2349 dnl Well, yes we could work around it...
2350 AC_DEFUN([CF_GNU_SOURCE],
2351 [
2352 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2353 AC_TRY_COMPILE([#include <sys/types.h>],[
2354 #ifndef _XOPEN_SOURCE
2355 make an error
2356 #endif],
2357         [cf_cv_gnu_source=no],
2358         [cf_save="$CPPFLAGS"
2359          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2360          AC_TRY_COMPILE([#include <sys/types.h>],[
2361 #ifdef _XOPEN_SOURCE
2362 make an error
2363 #endif],
2364         [cf_cv_gnu_source=no],
2365         [cf_cv_gnu_source=yes])
2366         CPPFLAGS="$cf_save"
2367         ])
2368 ])
2369 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2370 ])dnl
2371 dnl ---------------------------------------------------------------------------
2372 dnl CF_GPP_LIBRARY version: 10 updated: 2010/05/29 16:31:02
2373 dnl --------------
2374 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2375 dnl problem :-).  If we have the compiler but no library, we'll be able to
2376 dnl configure, but won't be able to build the c++ demo program.
2377 AC_DEFUN([CF_GPP_LIBRARY],
2378 [
2379 cf_cxx_library=unknown
2380 case $cf_cv_system_name in #(vi
2381 os2*) #(vi
2382         cf_gpp_libname=gpp
2383         ;;
2384 *)
2385         cf_gpp_libname=g++
2386         ;;
2387 esac
2388 if test "$GXX" = yes; then
2389         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2390         cf_save="$LIBS"
2391         CF_ADD_LIB($cf_gpp_libname)
2392         AC_TRY_LINK([
2393 #include <$cf_gpp_libname/builtin.h>
2394         ],
2395         [two_arg_error_handler_t foo2 = lib_error_handler],
2396         [cf_cxx_library=yes
2397          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2398          if test "$cf_gpp_libname" = cpp ; then
2399             AC_DEFINE(HAVE_GPP_BUILTIN_H)
2400          else
2401             AC_DEFINE(HAVE_GXX_BUILTIN_H)
2402          fi],
2403         [AC_TRY_LINK([
2404 #include <builtin.h>
2405         ],
2406         [two_arg_error_handler_t foo2 = lib_error_handler],
2407         [cf_cxx_library=yes
2408          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2409          AC_DEFINE(HAVE_BUILTIN_H)],
2410         [cf_cxx_library=no])])
2411         LIBS="$cf_save"
2412         AC_MSG_RESULT($cf_cxx_library)
2413 fi
2414 ])dnl
2415 dnl ---------------------------------------------------------------------------
2416 dnl CF_GXX_VERSION version: 6 updated: 2010/10/23 15:44:18
2417 dnl --------------
2418 dnl Check for version of g++
2419 AC_DEFUN([CF_GXX_VERSION],[
2420 AC_REQUIRE([AC_PROG_CPP])
2421 GXX_VERSION=none
2422 if test "$GXX" = yes; then
2423         AC_MSG_CHECKING(version of g++)
2424         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2425         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2426         AC_MSG_RESULT($GXX_VERSION)
2427 fi
2428 ])dnl
2429 dnl ---------------------------------------------------------------------------
2430 dnl CF_GXX_WARNINGS version: 6 updated: 2010/08/14 18:25:37
2431 dnl ---------------
2432 dnl Check if the compiler supports useful warning options.
2433 dnl
2434 dnl Most of gcc's options apply to g++, except:
2435 dnl     -Wbad-function-cast
2436 dnl     -Wmissing-declarations
2437 dnl     -Wnested-externs
2438 dnl
2439 dnl Omit a few (for now):
2440 dnl     -Winline
2441 dnl
2442 dnl Parameter:
2443 dnl     $1 is an optional list of g++ warning flags that a particular
2444 dnl             application might want to use, e.g., "no-unused" for
2445 dnl             -Wno-unused
2446 dnl Special:
2447 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2448 dnl
2449 AC_DEFUN([CF_GXX_WARNINGS],
2450 [
2451
2452 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2453
2454 AC_REQUIRE([CF_GXX_VERSION])
2455
2456 AC_LANG_SAVE
2457 AC_LANG_CPLUSPLUS
2458
2459 cat > conftest.$ac_ext <<EOF
2460 #line __oline__ "configure"
2461 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2462 EOF
2463
2464 if test "$INTEL_CPLUSPLUS" = yes
2465 then
2466 # The "-wdXXX" options suppress warnings:
2467 # remark #1419: external declaration in primary source file
2468 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2469 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2470 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2471 # remark #193: zero used for undefined preprocessing identifier
2472 # remark #593: variable "curs_sb_left_arrow" was set but never used
2473 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2474 # remark #869: parameter "tw" was never referenced
2475 # remark #981: operands are evaluated in unspecified order
2476 # warning #269: invalid format string conversion
2477
2478         AC_CHECKING([for $CC warning options])
2479         cf_save_CXXFLAGS="$CXXFLAGS"
2480         EXTRA_CXXFLAGS="-Wall"
2481         for cf_opt in \
2482                 wd1419 \
2483                 wd1682 \
2484                 wd1683 \
2485                 wd1684 \
2486                 wd193 \
2487                 wd279 \
2488                 wd593 \
2489                 wd810 \
2490                 wd869 \
2491                 wd981
2492         do
2493                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2494                 if AC_TRY_EVAL(ac_compile); then
2495                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2496                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2497                 fi
2498         done
2499         CXXFLAGS="$cf_save_CXXFLAGS"
2500
2501 elif test "$GXX" = yes
2502 then
2503         AC_CHECKING([for $CXX warning options])
2504         cf_save_CXXFLAGS="$CXXFLAGS"
2505         EXTRA_CXXFLAGS="-W -Wall"
2506         cf_gxx_extra_warnings=""
2507         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2508         case "$GCC_VERSION" in
2509         [[1-2]].*)
2510                 ;;
2511         *)
2512                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2513                 ;;
2514         esac
2515         for cf_opt in \
2516                 Wabi \
2517                 fabi-version=0 \
2518                 Woverloaded-virtual \
2519                 Wsign-promo \
2520                 Wsynth \
2521                 Wold-style-cast \
2522                 Wcast-align \
2523                 Wcast-qual \
2524                 Wmissing-prototypes \
2525                 Wpointer-arith \
2526                 Wshadow \
2527                 Wstrict-prototypes \
2528                 Wundef $cf_gxx_extra_warnings $1
2529         do
2530                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2531                 if AC_TRY_EVAL(ac_compile); then
2532                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2533                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2534                 else
2535                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2536                 fi
2537         done
2538         CXXFLAGS="$cf_save_CXXFLAGS"
2539 fi
2540
2541 rm -rf conftest*
2542 AC_LANG_RESTORE
2543 AC_SUBST(EXTRA_CXXFLAGS)
2544 ])dnl
2545 dnl ---------------------------------------------------------------------------
2546 dnl CF_HASHED_DB version: 4 updated: 2010/05/29 16:31:02
2547 dnl ------------
2548 dnl Look for an instance of the Berkeley hashed database.
2549 dnl
2550 dnl $1 = optional parameter, to specify install-prefix for the database.
2551 AC_DEFUN([CF_HASHED_DB],
2552 [
2553 ifelse([$1],,,[
2554 case $1 in #(vi
2555 yes|*able*) #(vi
2556     ;;
2557 *)
2558     if test -d "$1" ; then
2559         CF_ADD_INCDIR($1/include)
2560         CF_ADD_LIBDIR($1/lib)
2561     fi
2562 esac
2563 ])
2564 AC_CHECK_HEADER(db.h,[
2565 CF_HASHED_DB_VERSION
2566 if test "$cf_cv_hashed_db_version" = unknown ; then
2567         AC_MSG_ERROR(Cannot determine version of db)
2568 else
2569         CF_HASHED_DB_LIBS
2570         if test "$cf_cv_hashed_db_libs" = unknown ; then
2571                 AC_MSG_ERROR(Cannot determine library for db)
2572         elif test "$cf_cv_hashed_db_libs" != default ; then
2573                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2574         fi
2575 fi
2576 ],[
2577         AC_MSG_ERROR(Cannot find db.h)
2578 ])
2579 ])dnl
2580 dnl ---------------------------------------------------------------------------
2581 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2582 dnl -----------------
2583 dnl Given that we have the header and version for hashed database, find the
2584 dnl library information.
2585 AC_DEFUN([CF_HASHED_DB_LIBS],
2586 [
2587 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2588 cf_cv_hashed_db_libs=unknown
2589 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2590 do
2591         cf_save_libs="$LIBS"
2592         if test -n "$cf_db_libs"; then
2593                 CF_ADD_LIB($cf_db_libs)
2594         fi
2595         CF_MSG_LOG(checking for library "$cf_db_libs")
2596         AC_TRY_LINK([
2597 $ac_includes_default
2598 #include <db.h>
2599 ],[
2600         char *path = "/tmp/foo";
2601 #ifdef DB_VERSION_MAJOR
2602 #if DB_VERSION_MAJOR >= 4
2603         DB *result = 0;
2604         db_create(&result, NULL, 0);
2605         result->open(result,
2606                 NULL,
2607                 path,
2608                 path,
2609                 DB_HASH,
2610                 DB_CREATE,
2611                 0644);
2612 #elif DB_VERSION_MAJOR >= 3
2613         DB *result = 0;
2614         db_create(&result, NULL, 0);
2615         result->open(result,
2616                 path,
2617                 path,
2618                 DB_HASH,
2619                 DB_CREATE,
2620                 0644);
2621 #elif DB_VERSION_MAJOR >= 2
2622         DB *result = 0;
2623         db_open(path,
2624                 DB_HASH,
2625                 DB_CREATE,
2626                 0644,
2627                 (DB_ENV *) 0,
2628                 (DB_INFO *) 0,
2629                 &result);
2630 #endif /* DB_VERSION_MAJOR */
2631 #else
2632         DB *result = dbopen(path,
2633                      2,
2634                      0644,
2635                      DB_HASH,
2636                      0);
2637 #endif
2638         ${cf_cv_main_return:-return}(result != 0)
2639 ],[
2640         if test -n "$cf_db_libs" ; then
2641                 cf_cv_hashed_db_libs=$cf_db_libs
2642         else
2643                 cf_cv_hashed_db_libs=default
2644         fi
2645         LIBS="$cf_save_libs"
2646         break
2647 ])
2648         LIBS="$cf_save_libs"
2649 done
2650 ])
2651 ])dnl
2652 dnl ---------------------------------------------------------------------------
2653 dnl CF_HASHED_DB_VERSION version: 3 updated: 2007/12/01 15:01:37
2654 dnl --------------------
2655 dnl Given that we have the header file for hashed database, find the version
2656 dnl information.
2657 AC_DEFUN([CF_HASHED_DB_VERSION],
2658 [
2659 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2660 cf_cv_hashed_db_version=unknown
2661
2662 for cf_db_version in 1 2 3 4 5
2663 do
2664         CF_MSG_LOG(checking for db version $cf_db_version)
2665         AC_TRY_COMPILE([
2666 $ac_includes_default
2667 #include <db.h>
2668
2669 #ifdef DB_VERSION_MAJOR
2670         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2671 #if $cf_db_version == DB_VERSION_MAJOR
2672         /* ok */
2673 #else
2674         make an error
2675 #endif
2676 #else
2677 #if $cf_db_version == 1
2678         /* ok: assuming this is DB 1.8.5 */
2679 #else
2680         make an error
2681 #endif
2682 #endif
2683 ],[DBT *foo = 0],[
2684         cf_cv_hashed_db_version=$cf_db_version
2685         break
2686         ])
2687 done
2688 ])
2689 ])dnl
2690 dnl ---------------------------------------------------------------------------
2691 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
2692 dnl --------------
2693 dnl Construct a search-list of directories for a nonstandard header-file
2694 dnl
2695 dnl Parameters
2696 dnl     $1 = the variable to return as result
2697 dnl     $2 = the package name
2698 AC_DEFUN([CF_HEADER_PATH],
2699 [
2700 $1=
2701
2702 # collect the current set of include-directories from compiler flags
2703 cf_header_path_list=""
2704 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2705         for cf_header_path in $CPPFLAGS $CFLAGS
2706         do
2707                 case $cf_header_path in #(vi
2708                 -I*)
2709                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2710                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2711                         cf_header_path_list="$cf_header_path_list [$]$1"
2712                         ;;
2713                 esac
2714         done
2715 fi
2716
2717 # add the variations for the package we are looking for
2718 CF_SUBDIR_PATH($1,$2,include)
2719
2720 test "$includedir" != NONE && \
2721 test "$includedir" != "/usr/include" && \
2722 test -d "$includedir" && {
2723         test -d $includedir &&    $1="[$]$1 $includedir"
2724         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2725 }
2726
2727 test "$oldincludedir" != NONE && \
2728 test "$oldincludedir" != "/usr/include" && \
2729 test -d "$oldincludedir" && {
2730         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2731         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2732 }
2733
2734 $1="[$]$1 $cf_header_path_list"
2735 ])dnl
2736 dnl ---------------------------------------------------------------------------
2737 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2738 dnl ---------------
2739 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2740 AC_DEFUN([CF_HELP_MESSAGE],
2741 [AC_DIVERT_HELP([$1])dnl
2742 ])dnl
2743 dnl ---------------------------------------------------------------------------
2744 dnl CF_INCLUDE_DIRS version: 6 updated: 2009/01/06 19:37:40
2745 dnl ---------------
2746 dnl Construct the list of include-options according to whether we're building
2747 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
2748 dnl with gcc, don't append the includedir if it happens to be /usr/include,
2749 dnl since that usually breaks gcc's shadow-includes.
2750 AC_DEFUN([CF_INCLUDE_DIRS],
2751 [
2752 CPPFLAGS="$CPPFLAGS -I. -I../include"
2753 if test "$srcdir" != "."; then
2754         CPPFLAGS="$CPPFLAGS -I\${srcdir}/../include"
2755 fi
2756 if test "$GCC" != yes; then
2757         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2758 elif test "$includedir" != "/usr/include"; then
2759         if test "$includedir" = '${prefix}/include' ; then
2760                 if test $prefix != /usr ; then
2761                         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2762                 fi
2763         else
2764                 CPPFLAGS="$CPPFLAGS -I\${includedir}"
2765         fi
2766 fi
2767 AC_SUBST(CPPFLAGS)
2768 ])dnl
2769 dnl ---------------------------------------------------------------------------
2770 dnl CF_INTEL_COMPILER version: 4 updated: 2010/05/26 05:38:42
2771 dnl -----------------
2772 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2773 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2774 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2775 dnl
2776 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2777 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2778 dnl the wrappers for gcc and g++ warnings.
2779 dnl
2780 dnl $1 = GCC (default) or GXX
2781 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2782 dnl $3 = CFLAGS (default) or CXXFLAGS
2783 AC_DEFUN([CF_INTEL_COMPILER],[
2784 ifelse([$2],,INTEL_COMPILER,[$2])=no
2785
2786 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2787         case $host_os in
2788         linux*|gnu*)
2789                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2790                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2791                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2792                 AC_TRY_COMPILE([],[
2793 #ifdef __INTEL_COMPILER
2794 #else
2795 make an error
2796 #endif
2797 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2798 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
2799 ],[])
2800                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2801                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2802                 ;;
2803         esac
2804 fi
2805 ])dnl
2806 dnl ---------------------------------------------------------------------------
2807 dnl CF_ISASCII version: 3 updated: 2000/08/12 23:18:52
2808 dnl ----------
2809 dnl Check if we have either a function or macro for 'isascii()'.
2810 AC_DEFUN([CF_ISASCII],
2811 [
2812 AC_MSG_CHECKING(for isascii)
2813 AC_CACHE_VAL(cf_cv_have_isascii,[
2814         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2815         [cf_cv_have_isascii=yes],
2816         [cf_cv_have_isascii=no])
2817 ])dnl
2818 AC_MSG_RESULT($cf_cv_have_isascii)
2819 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII)
2820 ])dnl
2821 dnl ---------------------------------------------------------------------------
2822 dnl CF_LARGEFILE version: 7 updated: 2007/06/02 11:58:50
2823 dnl ------------
2824 dnl Add checks for large file support.
2825 AC_DEFUN([CF_LARGEFILE],[
2826 ifdef([AC_FUNC_FSEEKO],[
2827     AC_SYS_LARGEFILE
2828     if test "$enable_largefile" != no ; then
2829         AC_FUNC_FSEEKO
2830
2831         # Normally we would collect these definitions in the config.h,
2832         # but (like _XOPEN_SOURCE), some environments rely on having these
2833         # defined before any of the system headers are included.  Another
2834         # case comes up with C++, e.g., on AIX the compiler compiles the
2835         # header files by themselves before looking at the body files it is
2836         # told to compile.  For ncurses, those header files do not include
2837         # the config.h
2838         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2839         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2840         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2841
2842         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2843                 AC_TRY_COMPILE([
2844 #include <sys/types.h>
2845 #include <dirent.h>
2846                 ],[
2847                 /* if transitional largefile support is setup, this is true */
2848                 extern struct dirent64 * readdir(DIR *);
2849                 struct dirent64 *x = readdir((DIR *)0);
2850                 struct dirent *y = readdir((DIR *)0);
2851                 int z = x - y;
2852                 ],
2853                 [cf_cv_struct_dirent64=yes],
2854                 [cf_cv_struct_dirent64=no])
2855         ])
2856         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64)
2857     fi
2858 ])
2859 ])
2860 dnl ---------------------------------------------------------------------------
2861 dnl CF_LDFLAGS_STATIC version: 10 updated: 2011/09/24 12:51:48
2862 dnl -----------------
2863 dnl Check for compiler/linker flags used to temporarily force usage of static
2864 dnl libraries.  This depends on the compiler and platform.  Use this to help
2865 dnl ensure that the linker picks up a given library based on its position in
2866 dnl the list of linker options and libraries.
2867 AC_DEFUN([CF_LDFLAGS_STATIC],[
2868
2869 if test "$GCC" = yes ; then
2870         case $cf_cv_system_name in #(
2871         OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)         #( vi
2872                 LDFLAGS_STATIC=
2873                 LDFLAGS_SHARED=
2874                 ;;
2875     *)  #( normally, except when broken
2876         LDFLAGS_STATIC=-static
2877         LDFLAGS_SHARED=-dynamic
2878         ;;
2879     esac
2880 else
2881         case $cf_cv_system_name in #(
2882         aix[[4-7]]*)    #( from ld manpage
2883                 LDFLAGS_STATIC=-bstatic
2884                 LDFLAGS_SHARED=-bdynamic
2885                 ;;
2886         hpux*)          #( from ld manpage for hpux10.20, hpux11.11
2887                 # We could also use just "archive" and "shared".
2888                 LDFLAGS_STATIC=-Wl,-a,archive_shared
2889                 LDFLAGS_SHARED=-Wl,-a,shared_archive
2890                 ;;
2891         irix*)          #( from ld manpage IRIX64
2892                 LDFLAGS_STATIC=-Bstatic
2893                 LDFLAGS_SHARED=-Bdynamic
2894                 ;;
2895         osf[[45]]*)     #( from ld manpage osf4.0d, osf5.1
2896                 # alternative "-oldstyle_liblookup" (not in cc manpage)
2897                 LDFLAGS_STATIC=-noso
2898                 LDFLAGS_SHARED=-so_archive
2899                 ;;
2900         solaris2*)
2901                 LDFLAGS_STATIC=-Bstatic
2902                 LDFLAGS_SHARED=-Bdynamic
2903                 ;;
2904         esac
2905 fi
2906
2907 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
2908 then
2909         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
2910
2911         rm -f libconftest.a
2912         cat >conftest.$ac_ext <<EOF
2913 #line __oline__ "configure"
2914 #include <stdio.h>
2915 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
2916 EOF
2917         if AC_TRY_EVAL(ac_compile) ; then
2918                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
2919                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
2920         fi
2921         rm -f conftest.*
2922
2923         cf_save_LIBS="$LIBS"
2924
2925         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
2926         AC_TRY_LINK([
2927 #line __oline__ "configure"
2928 #include <stdio.h>
2929 int cf_ldflags_static(FILE *fp);
2930 ],[
2931         return cf_ldflags_static(stdin);
2932 ],[
2933         # some linkers simply ignore the -dynamic
2934         case x`file conftest$ac_exeext 2>/dev/null` in #(vi
2935         *static*) # (vi
2936                 cf_ldflags_static=no
2937                 ;;
2938         *)
2939                 cf_ldflags_static=yes
2940                 ;;
2941         esac
2942 ],[cf_ldflags_static=no])
2943
2944         rm -f libconftest.*
2945         LIBS="$cf_save_LIBS"
2946
2947         AC_MSG_RESULT($cf_ldflags_static)
2948
2949         if test $cf_ldflags_static != yes
2950         then
2951                 LDFLAGS_STATIC=
2952                 LDFLAGS_SHARED=
2953         fi
2954 else
2955         LDFLAGS_STATIC=
2956         LDFLAGS_SHARED=
2957 fi
2958
2959 AC_SUBST(LDFLAGS_STATIC)
2960 AC_SUBST(LDFLAGS_SHARED)
2961 ])
2962 dnl ---------------------------------------------------------------------------
2963 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
2964 dnl ---------------
2965 dnl For the given system and compiler, find the compiler flags to pass to the
2966 dnl loader to use the "rpath" feature.
2967 AC_DEFUN([CF_LD_RPATH_OPT],
2968 [
2969 AC_REQUIRE([CF_CHECK_CACHE])
2970
2971 LD_RPATH_OPT=
2972 AC_MSG_CHECKING(for an rpath option)
2973 case $cf_cv_system_name in #(vi
2974 irix*) #(vi
2975         if test "$GCC" = yes; then
2976                 LD_RPATH_OPT="-Wl,-rpath,"
2977         else
2978                 LD_RPATH_OPT="-rpath "
2979         fi
2980         ;;
2981 linux*|gnu*|k*bsd*-gnu) #(vi
2982         LD_RPATH_OPT="-Wl,-rpath,"
2983         ;;
2984 openbsd[[2-9]].*|mirbsd*) #(vi
2985         LD_RPATH_OPT="-Wl,-rpath,"
2986         ;;
2987 dragonfly*|freebsd*) #(vi
2988         LD_RPATH_OPT="-rpath "
2989         ;;
2990 netbsd*) #(vi
2991         LD_RPATH_OPT="-Wl,-rpath,"
2992         ;;
2993 osf*|mls+*) #(vi
2994         LD_RPATH_OPT="-rpath "
2995         ;;
2996 solaris2*) #(vi
2997         LD_RPATH_OPT="-R"
2998         ;;
2999 *)
3000         ;;
3001 esac
3002 AC_MSG_RESULT($LD_RPATH_OPT)
3003
3004 case "x$LD_RPATH_OPT" in #(vi
3005 x-R*)
3006         AC_MSG_CHECKING(if we need a space after rpath option)
3007         cf_save_LIBS="$LIBS"
3008         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3009         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3010         LIBS="$cf_save_LIBS"
3011         AC_MSG_RESULT($cf_rpath_space)
3012         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3013         ;;
3014 esac
3015 ])dnl
3016 dnl ---------------------------------------------------------------------------
3017 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
3018 dnl ---------------
3019 dnl Construct a search-list of directories for a nonstandard library-file
3020 dnl
3021 dnl Parameters
3022 dnl     $1 = the variable to return as result
3023 dnl     $2 = the package name
3024 AC_DEFUN([CF_LIBRARY_PATH],
3025 [
3026 $1=
3027 cf_library_path_list=""
3028 if test -n "${LDFLAGS}${LIBS}" ; then
3029         for cf_library_path in $LDFLAGS $LIBS
3030         do
3031                 case $cf_library_path in #(vi
3032                 -L*)
3033                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3034                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3035                         cf_library_path_list="$cf_library_path_list [$]$1"
3036                         ;;
3037                 esac
3038         done
3039 fi
3040
3041 CF_SUBDIR_PATH($1,$2,lib)
3042
3043 $1="$cf_library_path_list [$]$1"
3044 ])dnl
3045 dnl ---------------------------------------------------------------------------
3046 dnl CF_LIB_PREFIX version: 9 updated: 2012/01/21 19:28:10
3047 dnl -------------
3048 dnl Compute the library-prefix for the given host system
3049 dnl $1 = variable to set
3050 define([CF_LIB_PREFIX],
3051 [
3052         case $cf_cv_system_name in #(vi
3053         OS/2*|os2*) #(vi
3054         LIB_PREFIX=''
3055         ;;
3056         *)      LIB_PREFIX='lib'
3057         ;;
3058         esac
3059 ifelse($1,,,[$1=$LIB_PREFIX])
3060         AC_SUBST(LIB_PREFIX)
3061 ])dnl
3062 dnl ---------------------------------------------------------------------------
3063 dnl CF_LIB_RULES version: 64 updated: 2012/02/25 15:20:07
3064 dnl ------------
3065 dnl Append definitions and rules for the given models to the subdirectory
3066 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3067 dnl subdirectory is a library-source directory, modify the LIBS_TO_MAKE list in
3068 dnl the corresponding makefile to list the models that we'll generate.
3069 dnl
3070 dnl For shared libraries, make a list of symbolic links to construct when
3071 dnl generating each library.  The convention used for Linux is the simplest
3072 dnl one:
3073 dnl     lib<name>.so    ->
3074 dnl     lib<name>.so.<major>    ->
3075 dnl     lib<name>.so.<maj>.<minor>
3076 AC_DEFUN([CF_LIB_RULES],
3077 [
3078 cf_prefix=$LIB_PREFIX
3079 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3080
3081 case $cf_cv_shlib_version in #(vi
3082 cygdll|mingw)
3083         TINFO_NAME=$TINFO_ARG_SUFFIX
3084         TINFO_SUFFIX=.dll
3085         ;;
3086 esac
3087
3088 if test -n "$TINFO_SUFFIX" ; then
3089         case $TINFO_SUFFIX in
3090         tw*)
3091                 TINFO_NAME="${TINFO_NAME}tw"
3092                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw//'`
3093                 ;;
3094         t*)
3095                 TINFO_NAME="${TINFO_NAME}t"
3096                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t//'`
3097                 ;;
3098         w*)
3099                 TINFO_NAME="${TINFO_NAME}w"
3100                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w//'`
3101                 ;;
3102         esac
3103 fi
3104
3105 for cf_dir in $SRC_SUBDIRS
3106 do
3107         if test ! -d $srcdir/$cf_dir ; then
3108                 continue
3109         elif test -f $srcdir/$cf_dir/modules; then
3110
3111                 SHARED_LIB=
3112                 LIBS_TO_MAKE=
3113                 for cf_item in $cf_LIST_MODELS
3114                 do
3115                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3116                         if test $cf_item = shared ; then
3117                         if test "$cf_cv_do_symlinks" = yes ; then
3118                                 case "$cf_cv_shlib_version" in #(vi
3119                                 rel) #(vi
3120                                         case "$cf_cv_system_name" in #(vi
3121                                         darwin*)
3122                                         case .${LIB_SUFFIX} in
3123                                         .tw*)
3124                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3125                                                 cf_suffix=tw'.${REL_VERSION}'"$cf_suffix"
3126                                                 ;;
3127                                         .t*)
3128                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3129                                                 cf_suffix=t'.${REL_VERSION}'"$cf_suffix"
3130                                                 ;;
3131                                         .w*)
3132                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3133                                                 cf_suffix=w'.${REL_VERSION}'"$cf_suffix"
3134                                                 ;;
3135                                         *)
3136                                                 cf_suffix='.${REL_VERSION}'"$cf_suffix"
3137                                                 ;;
3138                                         esac
3139                                         ;; #(vi
3140                                         *) cf_suffix="$cf_suffix"'.${REL_VERSION}' ;;
3141                                         esac
3142                                         ;;
3143                                 abi)
3144                                         case "$cf_cv_system_name" in #(vi
3145                                         darwin*)
3146                                         case .${LIB_SUFFIX} in
3147                                         .tw*)
3148                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3149                                                 cf_suffix=tw'.${ABI_VERSION}'"$cf_suffix"
3150                                                 ;;
3151                                         .t*)
3152                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3153                                                 cf_suffix=t'.${ABI_VERSION}'"$cf_suffix"
3154                                                 ;;
3155                                         .w*)
3156                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3157                                                 cf_suffix=w'.${ABI_VERSION}'"$cf_suffix"
3158                                                 ;;
3159                                         *)
3160                                                 cf_suffix='.${ABI_VERSION}'"$cf_suffix"
3161                                                 ;;
3162                                         esac
3163                                         ;; #(vi
3164                                         *) cf_suffix="$cf_suffix"'.${ABI_VERSION}' ;;
3165                                         esac
3166                                         ;;
3167                                 esac
3168                         fi
3169                         # cygwin needs import library, and has unique naming convention
3170                         # use autodetected ${cf_prefix} for import lib and static lib, but
3171                         # use 'cyg' prefix for shared lib.
3172                         case $cf_cv_shlib_version in #(vi
3173                         cygdll) #(vi
3174                                 cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3175                                 LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/cyg${cf_dir}${cf_cygsuf}"
3176                                 continue
3177                                 ;;
3178                         mingw)
3179                                 cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3180                                 LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/lib${cf_dir}${cf_cygsuf}"
3181                                 continue
3182                                 ;;
3183                         esac
3184                         fi
3185                         LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/${cf_prefix}${cf_dir}${cf_suffix}"
3186                 done
3187
3188                 if test $cf_dir = ncurses ; then
3189                         cf_subsets="$LIB_SUBSETS"
3190                         cf_r_parts="$cf_subsets"
3191                         cf_liblist="$LIBS_TO_MAKE"
3192
3193                         while test -n "$cf_r_parts"
3194                         do
3195                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3196                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3197                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3198                                         cf_item=
3199                                         case $cf_l_parts in #(vi
3200                                         *termlib*) #(vi
3201                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3202                                                 ;;
3203                                         *ticlib*)
3204                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3205                                                 ;;
3206                                         *)
3207                                                 break
3208                                                 ;;
3209                                         esac
3210                                         if test -n "$cf_item"; then
3211                                                 LIBS_TO_MAKE="$cf_item $LIBS_TO_MAKE"
3212                                         fi
3213                                 else
3214                                         break
3215                                 fi
3216                         done
3217                 else
3218                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3219                 fi
3220
3221                 sed -e "s%@LIBS_TO_MAKE@%$LIBS_TO_MAKE%" \
3222                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3223                         $cf_dir/Makefile >$cf_dir/Makefile.out
3224                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3225
3226                 $AWK -f $srcdir/mk-0th.awk \
3227                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" \
3228                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3229
3230                 for cf_subset in $cf_subsets
3231                 do
3232                         cf_subdirs=
3233                         for cf_item in $cf_LIST_MODELS
3234                         do
3235                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3236                         CF_UPPER(cf_ITEM,$cf_item)
3237                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3238                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3239
3240                         # Test for case where we build libtinfo with a different name.
3241                         cf_libname=$cf_dir
3242                         if test $cf_dir = ncurses ; then
3243                                 case $cf_subset in
3244                                 *base*)
3245                                         cf_libname=${cf_libname}$LIB_SUFFIX
3246                                         ;;
3247                                 *termlib*)
3248                                         cf_libname=$TINFO_LIB_SUFFIX
3249                                         ;;
3250                                 ticlib*)
3251                                         cf_libname=$TICS_LIB_SUFFIX
3252                                         ;;
3253                                 esac
3254                         else
3255                                 cf_libname=${cf_libname}$LIB_SUFFIX
3256                         fi
3257                         if test -n "${DFT_ARG_SUFFIX}" ; then
3258                                 # undo $LIB_SUFFIX add-on in CF_LIB_SUFFIX
3259                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${LIB_SUFFIX}%%"`
3260                         fi
3261
3262                         # These dependencies really are for development, not
3263                         # builds, but they are useful in porting, too.
3264                         cf_depend="../include/ncurses_cfg.h"
3265                         if test "$srcdir" = "."; then
3266                                 cf_reldir="."
3267                         else
3268                                 cf_reldir="\${srcdir}"
3269                         fi
3270
3271                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3272                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3273                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3274                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3275                         fi
3276
3277                         cf_dir_suffix=
3278                         old_cf_suffix="$cf_suffix"
3279                         if test "$cf_cv_shlib_version_infix" = yes ; then
3280                         if test -n "$LIB_SUFFIX" ; then
3281                                 case $LIB_SUFFIX in
3282                                 tw*)
3283                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
3284                                         cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3285                                         cf_dir_suffix=tw
3286                                         ;;
3287                                 t*)
3288                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
3289                                         cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3290                                         cf_dir_suffix=t
3291                                         ;;
3292                                 w*)
3293                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
3294                                         cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3295                                         cf_dir_suffix=w
3296                                         ;;
3297                                 esac
3298                         fi
3299                         fi
3300
3301                         $AWK -f $srcdir/mk-1st.awk \
3302                                 name=${cf_libname}${cf_dir_suffix} \
3303                                 traces=$LIB_TRACING \
3304                                 MODEL=$cf_ITEM \
3305                                 model=$cf_subdir \
3306                                 prefix=$cf_prefix \
3307                                 suffix=$cf_suffix \
3308                                 subset=$cf_subset \
3309                                 driver=$cf_cv_term_driver \
3310                                 SymLink="$LN_S" \
3311                                 TermlibRoot=$TINFO_NAME \
3312                                 TermlibSuffix=$TINFO_SUFFIX \
3313                                 ShlibVer=$cf_cv_shlib_version \
3314                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3315                                 ReLink=${cf_cv_do_relink:-no} \
3316                                 DoLinks=$cf_cv_do_symlinks \
3317                                 rmSoLocs=$cf_cv_rm_so_locs \
3318                                 ldconfig="$LDCONFIG" \
3319                                 overwrite=$WITH_OVERWRITE \
3320                                 depend="$cf_depend" \
3321                                 host="$host" \
3322                                 libtool_version="$LIBTOOL_VERSION" \
3323                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3324
3325                         cf_suffix="$old_cf_suffix"
3326
3327                         for cf_subdir2 in $cf_subdirs lib
3328                         do
3329                                 test $cf_subdir = $cf_subdir2 && break
3330                         done
3331                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3332                         $AWK -f $srcdir/mk-2nd.awk \
3333                                 name=$cf_dir \
3334                                 traces=$LIB_TRACING \
3335                                 MODEL=$cf_ITEM \
3336                                 model=$cf_subdir \
3337                                 subset=$cf_subset \
3338                                 srcdir=$srcdir \
3339                                 echo=$WITH_ECHO \
3340                                 crenames=$cf_cv_prog_CC_c_o \
3341                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3342                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3343                         cf_subdirs="$cf_subdirs $cf_subdir"
3344                         done
3345                 done
3346         fi
3347
3348         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >>Makefile
3349 done
3350
3351 for cf_dir in $SRC_SUBDIRS
3352 do
3353         if test ! -d $srcdir/$cf_dir ; then
3354                 continue
3355         fi
3356
3357         if test -f $cf_dir/Makefile ; then
3358                 case "$cf_dir" in
3359                 Ada95) #(vi
3360                         echo 'libs \' >> Makefile
3361                         echo 'install.libs \' >> Makefile
3362                         echo 'uninstall.libs ::' >> Makefile
3363                         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >> Makefile
3364                         ;;
3365                 esac
3366         fi
3367
3368         if test -f $srcdir/$cf_dir/modules; then
3369                 echo >> Makefile
3370                 if test -f $srcdir/$cf_dir/headers; then
3371 cat >> Makefile <<CF_EOF
3372 install.includes \\
3373 uninstall.includes \\
3374 CF_EOF
3375                 fi
3376 if test "$cf_dir" != "c++" ; then
3377 echo 'lint \' >> Makefile
3378 fi
3379 cat >> Makefile <<CF_EOF
3380 libs \\
3381 lintlib \\
3382 install.libs \\
3383 uninstall.libs \\
3384 install.$cf_dir \\
3385 uninstall.$cf_dir ::
3386         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
3387 CF_EOF
3388         elif test -f $srcdir/$cf_dir/headers; then
3389 cat >> Makefile <<CF_EOF
3390
3391 libs \\
3392 install.libs \\
3393 uninstall.libs \\
3394 install.includes \\
3395 uninstall.includes ::
3396         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
3397 CF_EOF
3398 fi
3399 done
3400
3401 cat >> Makefile <<CF_EOF
3402
3403 install.libs uninstall.libs \\
3404 install.data uninstall.data ::
3405 $MAKE_TERMINFO  cd misc && \${MAKE} \${CF_MFLAGS} \[$]@
3406 CF_EOF
3407
3408 if test "x$cf_with_manpages" = xyes; then
3409 cat >> Makefile <<CF_EOF
3410
3411 install.man \\
3412 uninstall.man ::
3413         cd man && \${MAKE} \${CF_MFLAGS} \[$]@
3414 CF_EOF
3415 fi
3416
3417 cat >> Makefile <<CF_EOF
3418
3419 distclean ::
3420         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3421         rm -f headers.sh headers.sed mk_shared_lib.sh
3422         rm -f edit_man.* man_alias.*
3423         rm -rf \${DIRS_TO_MAKE}
3424 CF_EOF
3425
3426 # Special case: tack's manpage lives in its own directory.
3427 if test "x$cf_with_manpages" = xyes; then
3428 if test -d tack ; then
3429 if test -f $srcdir/$tack.h; then
3430 cat >> Makefile <<CF_EOF
3431
3432 install.man \\
3433 uninstall.man ::
3434         cd tack && \${MAKE} \${CF_MFLAGS} \[$]@
3435 CF_EOF
3436 fi
3437 fi
3438 fi
3439
3440 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3441 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3442 dnl anything, and will make it more standardized.  It's awkward to decide this
3443 dnl at configuration because of quoting, so we'll simply make all headers
3444 dnl installed via a script that can do the right thing.
3445
3446 rm -f headers.sed headers.sh
3447
3448 dnl ( generating this script makes the makefiles a little tidier :-)
3449 echo creating headers.sh
3450 cat >headers.sh <<CF_EOF
3451 #! /bin/sh
3452 # This shell script is generated by the 'configure' script.  It is invoked in a
3453 # subdirectory of the build tree.  It generates a sed-script in the parent
3454 # directory that is used to adjust includes for header files that reside in a
3455 # subdirectory of /usr/include, etc.
3456 PRG=""
3457 while test \[$]# != 3
3458 do
3459 PRG="\$PRG \[$]1"; shift
3460 done
3461 DST=\[$]1
3462 REF=\[$]2
3463 SRC=\[$]3
3464 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3465 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3466 echo installing \$SRC in \$DST
3467 CF_EOF
3468
3469 if test $WITH_CURSES_H = yes; then
3470         cat >>headers.sh <<CF_EOF
3471 case \$DST in
3472 /*/include/*)
3473         END=\`basename \$DST\`
3474         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3475         do
3476                 NAME=\`basename \$i\`
3477                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3478         done
3479         ;;
3480 *)
3481         echo "" >> \$TMPSED
3482         ;;
3483 esac
3484 CF_EOF
3485
3486 else
3487         cat >>headers.sh <<CF_EOF
3488 case \$DST in
3489 /*/include/*)
3490         END=\`basename \$DST\`
3491         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3492         do
3493                 NAME=\`basename \$i\`
3494                 if test "\$NAME" = "curses.h"
3495                 then
3496                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3497                         NAME=ncurses.h
3498                 fi
3499                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3500         done
3501         ;;
3502 *)
3503         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3504         ;;
3505 esac
3506 CF_EOF
3507 fi
3508 cat >>headers.sh <<CF_EOF
3509 rm -f \$TMPSRC
3510 sed -f \$TMPSED \$SRC > \$TMPSRC
3511 NAME=\`basename \$SRC\`
3512 CF_EOF
3513 if test $WITH_CURSES_H != yes; then
3514         cat >>headers.sh <<CF_EOF
3515 test "\$NAME" = "curses.h" && NAME=ncurses.h
3516 CF_EOF
3517 fi
3518 cat >>headers.sh <<CF_EOF
3519 # Just in case someone gzip'd manpages, remove the conflicting copy.
3520 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3521
3522 eval \$PRG \$TMPSRC \$DST/\$NAME
3523 rm -f \$TMPSRC \$TMPSED
3524 CF_EOF
3525
3526 chmod 0755 headers.sh
3527
3528 for cf_dir in $SRC_SUBDIRS
3529 do
3530         if test ! -d $srcdir/$cf_dir ; then
3531                 continue
3532         fi
3533
3534         if test -f $srcdir/$cf_dir/headers; then
3535                 $AWK -f $srcdir/mk-hdr.awk \
3536                         subset="$LIB_SUBSETS" \
3537                         compat="$WITH_CURSES_H" \
3538                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3539         fi
3540
3541         if test -f $srcdir/$cf_dir/modules; then
3542                 if test "$cf_dir" != "c++" ; then
3543                         cat >>$cf_dir/Makefile <<"CF_EOF"
3544 depend : ${AUTO_SRC}
3545         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3546
3547 # DO NOT DELETE THIS LINE -- make depend depends on it.
3548 CF_EOF
3549                 fi
3550         fi
3551 done
3552 AC_SUBST(LIBS_TO_MAKE)
3553 ])dnl
3554 dnl ---------------------------------------------------------------------------
3555 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3556 dnl -------------
3557 dnl Find the and soname for the given shared library.  Set the cache variable
3558 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3559 dnl variable to "unknown".
3560 dnl
3561 dnl $1 = headers
3562 dnl $2 = code
3563 dnl $3 = library name
3564 AC_DEFUN([CF_LIB_SONAME],
3565 [
3566 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3567
3568 cf_cv_$3_soname=unknown
3569 if test "$cross_compiling" != yes ; then
3570 cat >conftest.$ac_ext <<CF_EOF
3571 $1
3572 int main()
3573 {
3574 $2
3575         ${cf_cv_main_return:-return}(0);
3576 }
3577 CF_EOF
3578 cf_save_LIBS="$LIBS"
3579         CF_ADD_LIB($3)
3580         if AC_TRY_EVAL(ac_compile) ; then
3581                 if AC_TRY_EVAL(ac_link) ; then
3582                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3583                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3584                 fi
3585         fi
3586 rm -rf conftest*
3587 LIBS="$cf_save_LIBS"
3588 fi
3589 ])
3590 ])
3591 dnl ---------------------------------------------------------------------------
3592 dnl CF_LIB_SUFFIX version: 18 updated: 2012/02/25 15:20:07
3593 dnl -------------
3594 dnl Compute the library file-suffix from the given model name
3595 dnl $1 = model name
3596 dnl $2 = variable to set (the nominal library suffix)
3597 dnl $3 = dependency variable to set (actual filename)
3598 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3599 AC_DEFUN([CF_LIB_SUFFIX],
3600 [
3601         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3602         case $1 in #(vi
3603         libtool) #(vi
3604                 $2='.la'
3605                 $3=[$]$2
3606                 ;;
3607         normal) #(vi
3608                 $2='.a'
3609                 $3=[$]$2
3610                 ;;
3611         debug) #(vi
3612                 $2='_g.a'
3613                 $3=[$]$2
3614                 ;;
3615         profile) #(vi
3616                 $2='_p.a'
3617                 $3=[$]$2
3618                 ;;
3619         shared) #(vi
3620                 case $cf_cv_system_name in
3621                 aix[[5-7]]*) #(vi
3622                         $2='.a'
3623                         $3=[$]$2
3624                         ;;
3625                 cygwin*|mingw*) #(vi
3626                         $2='.dll'
3627                         $3='.dll.a'
3628                         ;;
3629                 darwin*) #(vi
3630                         $2='.dylib'
3631                         $3=[$]$2
3632                         ;;
3633                 hpux*) #(vi
3634                         case $target in
3635                         ia64*) #(vi
3636                                 $2='.so'
3637                                 $3=[$]$2
3638                                 ;;
3639                         *) #(vi
3640                                 $2='.sl'
3641                                 $3=[$]$2
3642                                 ;;
3643                         esac
3644                         ;;
3645                 *)      $2='.so'
3646                         $3=[$]$2
3647                         ;;
3648                 esac
3649         esac
3650         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3651         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
3652 ])dnl
3653 dnl ---------------------------------------------------------------------------
3654 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
3655 dnl -----------
3656 dnl Compute the string to append to -library from the given model name
3657 dnl $1 = model name
3658 dnl $2 = variable to set
3659 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3660 AC_DEFUN([CF_LIB_TYPE],
3661 [
3662         case $1 in
3663         libtool) $2=''   ;;
3664         normal)  $2=''   ;;
3665         debug)   $2='_g' ;;
3666         profile) $2='_p' ;;
3667         shared)  $2=''   ;;
3668         esac
3669         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3670 ])dnl
3671 dnl ---------------------------------------------------------------------------
3672 dnl CF_LINK_DATAONLY version: 9 updated: 2009/01/01 20:21:38
3673 dnl ----------------
3674 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3675 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3676 dnl have to provide wrappers for global tables to ensure they're linked
3677 dnl properly.
3678 AC_DEFUN([CF_LINK_DATAONLY],
3679 [
3680 AC_MSG_CHECKING([if data-only library module links])
3681 AC_CACHE_VAL(cf_cv_link_dataonly,[
3682         rm -f conftest.a
3683         cat >conftest.$ac_ext <<EOF
3684 #line __oline__ "configure"
3685 int     testdata[[3]] = { 123, 456, 789 };
3686 EOF
3687         if AC_TRY_EVAL(ac_compile) ; then
3688                 mv conftest.o data.o && \
3689                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3690         fi
3691         rm -f conftest.$ac_ext data.o
3692         cat >conftest.$ac_ext <<EOF
3693 #line __oline__ "configure"
3694 int     testfunc()
3695 {
3696 #if defined(NeXT)
3697         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3698 #else
3699         extern int testdata[[3]];
3700         return testdata[[0]] == 123
3701            &&  testdata[[1]] == 456
3702            &&  testdata[[2]] == 789;
3703 #endif
3704 }
3705 EOF
3706         if AC_TRY_EVAL(ac_compile); then
3707                 mv conftest.o func.o && \
3708                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3709         fi
3710         rm -f conftest.$ac_ext func.o
3711         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3712         cf_saveLIBS="$LIBS"
3713         LIBS="conftest.a $LIBS"
3714         AC_TRY_RUN([
3715         int main()
3716         {
3717                 extern int testfunc();
3718                 ${cf_cv_main_return:-return} (!testfunc());
3719         }
3720         ],
3721         [cf_cv_link_dataonly=yes],
3722         [cf_cv_link_dataonly=no],
3723         [cf_cv_link_dataonly=unknown])
3724         LIBS="$cf_saveLIBS"
3725         ])
3726 AC_MSG_RESULT($cf_cv_link_dataonly)
3727
3728 if test "$cf_cv_link_dataonly" = no ; then
3729         AC_DEFINE(BROKEN_LINKER)
3730         BROKEN_LINKER=1
3731 fi
3732
3733 ])dnl
3734 dnl ---------------------------------------------------------------------------
3735 dnl CF_LINK_FUNCS version: 7 updated: 2006/12/16 12:33:30
3736 dnl -------------
3737 dnl Most Unix systems have both link and symlink, a few don't have symlink.
3738 dnl A few non-Unix systems implement symlink, but not link.
3739 dnl A few non-systems implement neither (or have nonfunctional versions).
3740 AC_DEFUN([CF_LINK_FUNCS],
3741 [
3742 AC_CHECK_FUNCS( \
3743         remove \
3744         unlink )
3745
3746 if test "$cross_compiling" = yes ; then
3747         AC_CHECK_FUNCS( \
3748                 link \
3749                 symlink )
3750 else
3751         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
3752                 cf_cv_link_funcs=
3753                 for cf_func in link symlink ; do
3754                         AC_TRY_RUN([
3755 #include <sys/types.h>
3756 #include <sys/stat.h>
3757 #ifdef HAVE_UNISTD_H
3758 #include <unistd.h>
3759 #endif
3760 int main()
3761 {
3762         int fail = 0;
3763         char *src = "config.log";
3764         char *dst = "conftest.chk";
3765         struct stat src_sb;
3766         struct stat dst_sb;
3767
3768         stat(src, &src_sb);
3769         fail = ($cf_func("config.log", "conftest.chk") < 0)
3770             || (stat(dst, &dst_sb) < 0)
3771             || (dst_sb.st_mtime != src_sb.st_mtime);
3772 #ifdef HAVE_UNLINK
3773         unlink(dst);
3774 #else
3775         remove(dst);
3776 #endif
3777         ${cf_cv_main_return:-return} (fail);
3778 }
3779                         ],[
3780                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
3781                         eval 'ac_cv_func_'$cf_func'=yes'],[
3782                         eval 'ac_cv_func_'$cf_func'=no'],[
3783                         eval 'ac_cv_func_'$cf_func'=error'])
3784                 done
3785                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
3786         ])
3787         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK)
3788         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK)
3789 fi
3790 ])dnl
3791 dnl ---------------------------------------------------------------------------
3792 dnl CF_MAIN_RETURN version: 1 updated: 2006/12/10 09:51:54
3793 dnl --------------
3794 dnl Check if a return from main to the shell actually returns the same exit
3795 dnl code.  This is true for almost any POSIX environment.
3796 dnl
3797 dnl Some very old environments did not flush stdout, etc., on an exit.  That
3798 dnl would be a useful case to test for also.
3799 AC_DEFUN([CF_MAIN_RETURN],
3800 [
3801 cf_cv_main_return=return
3802 ])dnl
3803 dnl ---------------------------------------------------------------------------
3804 dnl CF_MAKEFLAGS version: 14 updated: 2011/03/31 19:29:46
3805 dnl ------------
3806 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
3807 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
3808 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
3809 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
3810 AC_DEFUN([CF_MAKEFLAGS],
3811 [
3812 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
3813         cf_cv_makeflags=''
3814         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
3815         do
3816                 cat >cf_makeflags.tmp <<CF_EOF
3817 SHELL = /bin/sh
3818 all :
3819         @ echo '.$cf_option'
3820 CF_EOF
3821                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
3822                 case "$cf_result" in
3823                 .*k)
3824                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
3825                         case "$cf_result" in
3826                         .*CC=*) cf_cv_makeflags=
3827                                 ;;
3828                         *)      cf_cv_makeflags=$cf_option
3829                                 ;;
3830                         esac
3831                         break
3832                         ;;
3833                 .-)     ;;
3834                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
3835                         ;;
3836                 esac
3837         done
3838         rm -f cf_makeflags.tmp
3839 ])
3840
3841 AC_SUBST(cf_cv_makeflags)
3842 ])dnl
3843 dnl ---------------------------------------------------------------------------
3844 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
3845 dnl ------------
3846 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
3847 dnl a monocase filesystem.
3848 AC_DEFUN([CF_MAKE_TAGS],[
3849 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
3850
3851 AC_CHECK_PROGS(CTAGS, exctags ctags)
3852 AC_CHECK_PROGS(ETAGS, exetags etags)
3853
3854 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
3855
3856 if test "$cf_cv_mixedcase" = yes ; then
3857         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
3858 else
3859         MAKE_UPPER_TAGS=no
3860 fi
3861
3862 if test "$MAKE_UPPER_TAGS" = yes ; then
3863         MAKE_UPPER_TAGS=
3864 else
3865         MAKE_UPPER_TAGS="#"
3866 fi
3867
3868 if test "$MAKE_LOWER_TAGS" = yes ; then
3869         MAKE_LOWER_TAGS=
3870 else
3871         MAKE_LOWER_TAGS="#"
3872 fi
3873
3874 AC_SUBST(CTAGS)
3875 AC_SUBST(ETAGS)
3876
3877 AC_SUBST(MAKE_UPPER_TAGS)
3878 AC_SUBST(MAKE_LOWER_TAGS)
3879 ])dnl
3880 dnl ---------------------------------------------------------------------------
3881 dnl CF_MANPAGE_FORMAT version: 9 updated: 2010/10/23 16:10:30
3882 dnl -----------------
3883 dnl Option to allow user to override automatic configuration of manpage format.
3884 dnl There are several special cases:
3885 dnl
3886 dnl     gzip - man checks for, can display gzip'd files
3887 dnl     compress - man checks for, can display compressed files
3888 dnl     BSDI - files in the cat-directories are suffixed ".0"
3889 dnl     formatted - installer should format (put files in cat-directory)
3890 dnl     catonly - installer should only format, e.g., for a turnkey system.
3891 dnl
3892 dnl There are other configurations which this macro does not test, e.g., HPUX's
3893 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
3894 dnl convention would not match our use).
3895 AC_DEFUN([CF_MANPAGE_FORMAT],
3896 [
3897 AC_REQUIRE([CF_PATHSEP])
3898 AC_MSG_CHECKING(format of man-pages)
3899
3900 AC_ARG_WITH(manpage-format,
3901         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
3902                           optionally formatted/catonly, e.g., gzip,formatted],
3903         [MANPAGE_FORMAT=$withval],
3904         [MANPAGE_FORMAT=unknown])
3905
3906 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
3907 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
3908
3909 cf_unknown=
3910
3911 case $MANPAGE_FORMAT in
3912 unknown)
3913   if test -z "$MANPATH" ; then
3914     MANPATH="/usr/man:/usr/share/man"
3915   fi
3916
3917   # look for the 'date' man-page (it's most likely to be installed!)
3918   MANPAGE_FORMAT=
3919   cf_preform=no
3920   cf_catonly=yes
3921   cf_example=date
3922
3923   IFS="${IFS:-  }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
3924   for cf_dir in $MANPATH; do
3925     test -z "$cf_dir" && cf_dir=/usr/man
3926     for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
3927     do
3928       cf_test=`echo $cf_name | sed -e 's/*//'`
3929       if test "x$cf_test" = "x$cf_name" ; then
3930
3931         case "$cf_name" in
3932         *.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
3933         *.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
3934         *.0)    MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
3935         *)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
3936         esac
3937
3938         case "$cf_name" in
3939         $cf_dir/man*)
3940           cf_catonly=no
3941           ;;
3942         $cf_dir/cat*)
3943           cf_preform=yes
3944           ;;
3945         esac
3946         break
3947       fi
3948
3949       # if we found a match in either man* or cat*, stop looking
3950       if test -n "$MANPAGE_FORMAT" ; then
3951         cf_found=no
3952         test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
3953         test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
3954         case "$cf_name" in
3955         $cf_dir/cat*)
3956           cf_found=yes
3957           ;;
3958         esac
3959         test $cf_found=yes && break
3960       fi
3961     done
3962     # only check the first directory in $MANPATH where we find manpages
3963     if test -n "$MANPAGE_FORMAT" ; then
3964        break
3965     fi
3966   done
3967   # if we did not find the example, just assume it is normal
3968   test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
3969   IFS="$ac_save_ifs"
3970   ;;
3971 *)
3972   for cf_option in $MANPAGE_FORMAT; do
3973      case $cf_option in #(vi
3974      gzip|compress|BSDI|normal|formatted|catonly)
3975        ;;
3976      *)
3977        cf_unknown="$cf_unknown $cf_option"
3978        ;;
3979      esac
3980   done
3981   ;;
3982 esac
3983
3984 AC_MSG_RESULT($MANPAGE_FORMAT)
3985 if test -n "$cf_unknown" ; then
3986   AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
3987 fi
3988 ])dnl
3989 dnl ---------------------------------------------------------------------------
3990 dnl CF_MANPAGE_RENAMES version: 7 updated: 2005/06/18 18:51:57
3991 dnl ------------------
3992 dnl The Debian people have their own naming convention for manpages.  This
3993 dnl option lets us override the name of the file containing renaming, or
3994 dnl disable it altogether.
3995 AC_DEFUN([CF_MANPAGE_RENAMES],
3996 [
3997 AC_MSG_CHECKING(for manpage renaming)
3998
3999 AC_ARG_WITH(manpage-renames,
4000         [  --with-manpage-renames  specify manpage-renaming],
4001         [MANPAGE_RENAMES=$withval],
4002         [MANPAGE_RENAMES=yes])
4003
4004 case ".$MANPAGE_RENAMES" in #(vi
4005 .no) #(vi
4006   ;;
4007 .|.yes)
4008   # Debian 'man' program?
4009   if test -f /etc/debian_version ; then
4010     MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
4011   else
4012     MANPAGE_RENAMES=no
4013   fi
4014   ;;
4015 esac
4016
4017 if test "$MANPAGE_RENAMES" != no ; then
4018   if test -f $srcdir/man/$MANPAGE_RENAMES ; then
4019     MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
4020   elif test ! -f $MANPAGE_RENAMES ; then
4021     AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
4022   fi
4023
4024   test ! -d man && mkdir man
4025
4026   # Construct a sed-script to perform renaming within man-pages
4027   if test -n "$MANPAGE_RENAMES" ; then
4028     test ! -d man && mkdir man
4029     sh $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
4030   fi
4031 fi
4032
4033 AC_MSG_RESULT($MANPAGE_RENAMES)
4034 AC_SUBST(MANPAGE_RENAMES)
4035 ])dnl
4036 dnl ---------------------------------------------------------------------------
4037 dnl CF_MANPAGE_SYMLINKS version: 5 updated: 2010/07/24 17:12:40
4038 dnl -------------------
4039 dnl Some people expect each tool to make all aliases for manpages in the
4040 dnl man-directory.  This accommodates the older, less-capable implementations
4041 dnl of 'man', and is optional.
4042 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4043 [
4044 AC_MSG_CHECKING(if manpage aliases will be installed)
4045
4046 AC_ARG_WITH(manpage-aliases,
4047         [  --with-manpage-aliases  specify manpage-aliases using .so],
4048         [MANPAGE_ALIASES=$withval],
4049         [MANPAGE_ALIASES=yes])
4050
4051 AC_MSG_RESULT($MANPAGE_ALIASES)
4052
4053 case "x$LN_S" in #(vi
4054 xln*) #(vi
4055         cf_use_symlinks=yes
4056         ;;
4057 *)
4058         cf_use_symlinks=no
4059         ;;
4060 esac
4061
4062 MANPAGE_SYMLINKS=no
4063 if test "$MANPAGE_ALIASES" = yes ; then
4064 AC_MSG_CHECKING(if manpage symlinks should be used)
4065
4066 AC_ARG_WITH(manpage-symlinks,
4067         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
4068         [MANPAGE_SYMLINKS=$withval],
4069         [MANPAGE_SYMLINKS=$cf_use_symlinks])
4070
4071 if test "$$cf_use_symlinks" = no; then
4072 if test "$MANPAGE_SYMLINKS" = yes ; then
4073         AC_MSG_WARN(cannot make symlinks, will use .so files)
4074         MANPAGE_SYMLINKS=no
4075 fi
4076 fi
4077
4078 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4079 fi
4080
4081 ])dnl
4082 dnl ---------------------------------------------------------------------------
4083 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4084 dnl --------------
4085 dnl This option causes manpages to be run through tbl(1) to generate tables
4086 dnl correctly.
4087 AC_DEFUN([CF_MANPAGE_TBL],
4088 [
4089 AC_MSG_CHECKING(for manpage tbl)
4090
4091 AC_ARG_WITH(manpage-tbl,
4092         [  --with-manpage-tbl      specify manpage processing with tbl],
4093         [MANPAGE_TBL=$withval],
4094         [MANPAGE_TBL=no])
4095
4096 AC_MSG_RESULT($MANPAGE_TBL)
4097 ])dnl
4098 dnl ---------------------------------------------------------------------------
4099 dnl CF_MAN_PAGES version: 40 updated: 2011/09/10 16:20:21
4100 dnl ------------
4101 dnl Try to determine if the man-pages on the system are compressed, and if
4102 dnl so, what format is used.  Use this information to construct a script that
4103 dnl will install man-pages.
4104 AC_DEFUN([CF_MAN_PAGES],
4105 [
4106 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4107 CF_MANPAGE_FORMAT
4108 CF_MANPAGE_RENAMES
4109 CF_MANPAGE_SYMLINKS
4110 CF_MANPAGE_TBL
4111
4112   if test "$prefix" = "NONE" ; then
4113      cf_prefix="$ac_default_prefix"
4114   else
4115      cf_prefix="$prefix"
4116   fi
4117
4118   case "$MANPAGE_FORMAT" in # (vi
4119   *catonly*) # (vi
4120     cf_format=yes
4121     cf_inboth=no
4122     ;;
4123   *formatted*) # (vi
4124     cf_format=yes
4125     cf_inboth=yes
4126     ;;
4127   *)
4128     cf_format=no
4129     cf_inboth=no
4130     ;;
4131   esac
4132
4133 test ! -d man && mkdir man
4134
4135 cf_so_strip=
4136 cf_compress=
4137 case "$MANPAGE_FORMAT" in #(vi
4138 *compress*) #(vi
4139         cf_so_strip="Z"
4140         cf_compress=compress
4141   ;;
4142 *gzip*)
4143         cf_so_strip="gz"
4144         cf_compress=gzip
4145   ;;
4146 esac
4147
4148 cf_edit_man=./edit_man.sh
4149 cf_man_alias=`pwd`/man_alias.sed
4150
4151 cat >$cf_edit_man <<CF_EOF
4152 #! /bin/sh
4153 # this script is generated by the configure-script CF_MAN_PAGES macro.
4154
4155 prefix="$cf_prefix"
4156 datadir="$datadir"
4157
4158 NCURSES_MAJOR="$NCURSES_MAJOR"
4159 NCURSES_MINOR="$NCURSES_MINOR"
4160 NCURSES_PATCH="$NCURSES_PATCH"
4161
4162 NCURSES_OSPEED="$NCURSES_OSPEED"
4163 TERMINFO="$TERMINFO"
4164
4165 INSTALL="$INSTALL"
4166 INSTALL_DATA="$INSTALL_DATA"
4167
4168 transform="$program_transform_name"
4169
4170 TMP=\${TMPDIR:=/tmp}/man\$\$
4171 trap "rm -f \$TMP" 0 1 2 5 15
4172
4173 form=\[$]1
4174 shift || exit 1
4175
4176 verb=\[$]1
4177 shift || exit 1
4178
4179 mandir=\[$]1
4180 shift || exit 1
4181
4182 srcdir=\[$]1
4183 top_srcdir=\[$]srcdir/..
4184 shift || exit 1
4185
4186 if test "\$form" = normal ; then
4187         if test "$cf_format" = yes ; then
4188         if test "$cf_inboth" = no ; then
4189                 sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4190                 exit $?
4191         fi
4192         fi
4193         cf_subdir=\$mandir/man
4194         cf_tables=$MANPAGE_TBL
4195 else
4196         cf_subdir=\$mandir/cat
4197         cf_tables=yes
4198 fi
4199
4200 # process the list of source-files
4201 for i in \[$]* ; do
4202 case \$i in #(vi
4203 *.orig|*.rej) ;; #(vi
4204 *.[[0-9]]*)
4205         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4206         if test \$verb = installing ; then
4207         if test ! -d \$cf_subdir\${section} ; then
4208                 mkdir -p \$cf_subdir\$section
4209         fi
4210         fi
4211
4212         # replace variables in man page
4213         if test ! -f $cf_man_alias ; then
4214 cat >>$cf_man_alias <<-CF_EOF2
4215                 s,@DATADIR@,\$datadir,g
4216                 s,@TERMINFO@,\$TERMINFO,g
4217                 s,@NCURSES_MAJOR@,\$NCURSES_MAJOR,g
4218                 s,@NCURSES_MINOR@,\$NCURSES_MINOR,g
4219                 s,@NCURSES_PATCH@,\$NCURSES_PATCH,g
4220                 s,@NCURSES_OSPEED@,\$NCURSES_OSPEED,g
4221 CF_EOF
4222         ifelse($1,,,[
4223         for cf_name in $1
4224         do
4225                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4226                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4227 cat >>$cf_edit_man <<-CF_EOF
4228                 s,@$cf_NAME@,$cf_name,g
4229 CF_EOF
4230         done
4231         ])
4232 cat >>$cf_edit_man <<CF_EOF
4233 CF_EOF2
4234                 echo "...made $cf_man_alias"
4235         fi
4236
4237         aliases=
4238         cf_source=\`basename \$i\`
4239         inalias=\$cf_source
4240         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4241         if test ! -f \$inalias ; then
4242                 echo .. skipped \$cf_source
4243                 continue
4244         fi
4245 CF_EOF
4246
4247 if test "$MANPAGE_ALIASES" != no ; then
4248 cat >>$cf_edit_man <<CF_EOF
4249         nCurses=ignore.3x
4250         test $with_curses_h = yes && nCurses=ncurses.3x
4251         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4252 CF_EOF
4253 fi
4254
4255 if test "$MANPAGE_RENAMES" = no ; then
4256 cat >>$cf_edit_man <<CF_EOF
4257         # perform program transformations for section 1 man pages
4258         if test \$section = 1 ; then
4259                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4260         else
4261                 cf_target=\$cf_subdir\${section}/\$cf_source
4262         fi
4263 CF_EOF
4264 else
4265 cat >>$cf_edit_man <<CF_EOF
4266         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4267         if test -z "\$cf_target" ; then
4268                 echo '? missing rename for '\$cf_source
4269                 cf_target="\$cf_source"
4270         fi
4271         cf_target="\$cf_subdir\${section}/\${cf_target}"
4272
4273 CF_EOF
4274 fi
4275
4276 cat >>$cf_edit_man <<CF_EOF
4277         sed     -f $cf_man_alias \\
4278 CF_EOF
4279
4280 if test -f $MANPAGE_RENAMES ; then
4281 cat >>$cf_edit_man <<CF_EOF
4282                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4283 CF_EOF
4284 else
4285 cat >>$cf_edit_man <<CF_EOF
4286                 < \$i >\$TMP
4287 CF_EOF
4288 fi
4289
4290 cat >>$cf_edit_man <<CF_EOF
4291 if test \$cf_tables = yes ; then
4292         tbl \$TMP >\$TMP.out
4293         mv \$TMP.out \$TMP
4294 fi
4295 CF_EOF
4296
4297 if test $with_overwrite != yes ; then
4298 cat >>$cf_edit_man <<CF_EOF
4299         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
4300         mv \$TMP.out \$TMP
4301 CF_EOF
4302 fi
4303
4304 if test $with_curses_h != yes ; then
4305 cat >>$cf_edit_man <<CF_EOF
4306         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4307         mv \$TMP.out \$TMP
4308 CF_EOF
4309 fi
4310
4311 cat >>$cf_edit_man <<CF_EOF
4312         if test \$form = format ; then
4313                 nroff -man \$TMP >\$TMP.out
4314                 mv \$TMP.out \$TMP
4315         fi
4316 CF_EOF
4317
4318 if test -n "$cf_compress" ; then
4319 cat >>$cf_edit_man <<CF_EOF
4320         if test \$verb = installing ; then
4321         if ( $cf_compress -f \$TMP )
4322         then
4323                 mv \$TMP.$cf_so_strip \$TMP
4324         fi
4325         fi
4326         cf_target="\$cf_target.$cf_so_strip"
4327 CF_EOF
4328 fi
4329
4330 case "$MANPAGE_FORMAT" in #(vi
4331 *BSDI*)
4332 cat >>$cf_edit_man <<CF_EOF
4333         if test \$form = format ; then
4334                 # BSDI installs only .0 suffixes in the cat directories
4335                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
4336         fi
4337 CF_EOF
4338   ;;
4339 esac
4340
4341 cat >>$cf_edit_man <<CF_EOF
4342         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
4343         if test \$verb = installing ; then
4344                 echo \$verb \$cf_target
4345                 \$INSTALL_DATA \$TMP \$cf_target
4346                 test -d \$cf_subdir\${section} &&
4347                 test -n "\$aliases" && (
4348                         cd \$cf_subdir\${section} && (
4349                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
4350                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
4351                                 cf_target=\`basename \$cf_target\`
4352                                 for cf_alias in \$aliases
4353                                 do
4354                                         if test \$section = 1 ; then
4355                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4356                                         fi
4357
4358                                         if test "$MANPAGE_SYMLINKS" = yes ; then
4359                                                 if test -f \$cf_alias\${suffix} ; then
4360                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
4361                                                         then
4362                                                                 continue
4363                                                         fi
4364                                                 fi
4365                                                 echo .. \$verb alias \$cf_alias\${suffix}
4366 CF_EOF
4367 case "x$LN_S" in #(vi
4368 *-f) #(vi
4369 cat >>$cf_edit_man <<CF_EOF
4370                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4371 CF_EOF
4372         ;;
4373 *)
4374 cat >>$cf_edit_man <<CF_EOF
4375                                                 rm -f \$cf_alias\${suffix}
4376                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4377 CF_EOF
4378         ;;
4379 esac
4380 cat >>$cf_edit_man <<CF_EOF
4381                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
4382                                                 echo ".so \$cf_source" >\$TMP
4383 CF_EOF
4384 if test -n "$cf_compress" ; then
4385 cat >>$cf_edit_man <<CF_EOF
4386                                                 if test -n "$cf_so_strip" ; then
4387                                                         $cf_compress -f \$TMP
4388                                                         mv \$TMP.$cf_so_strip \$TMP
4389                                                 fi
4390 CF_EOF
4391 fi
4392 cat >>$cf_edit_man <<CF_EOF
4393                                                 echo .. \$verb alias \$cf_alias\${suffix}
4394                                                 rm -f \$cf_alias\${suffix}
4395                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
4396                                         fi
4397                                 done
4398                         )
4399                 )
4400         elif test \$verb = removing ; then
4401                 test -f \$cf_target && (
4402                         echo \$verb \$cf_target
4403                         rm -f \$cf_target
4404                 )
4405                 test -d \$cf_subdir\${section} &&
4406                 test -n "\$aliases" && (
4407                         cd \$cf_subdir\${section} && (
4408                                 for cf_alias in \$aliases
4409                                 do
4410                                         if test \$section = 1 ; then
4411                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4412                                         fi
4413
4414                                         echo .. \$verb alias \$cf_alias\${suffix}
4415                                         rm -f \$cf_alias\${suffix}
4416                                 done
4417                         )
4418                 )
4419         else
4420 #               echo ".hy 0"
4421                 cat \$TMP
4422         fi
4423         ;;
4424 esac
4425 done
4426
4427 if test $cf_inboth = yes ; then
4428 if test \$form != format ; then
4429         sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4430 fi
4431 fi
4432
4433 exit 0
4434 CF_EOF
4435 chmod 755 $cf_edit_man
4436
4437 ])dnl
4438 dnl ---------------------------------------------------------------------------
4439 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
4440 dnl -----------
4441 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
4442 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
4443 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
4444 AC_DEFUN([CF_MATH_LIB],
4445 [
4446 AC_CACHE_CHECK(if -lm needed for math functions,
4447         cf_cv_need_libm,[
4448         AC_TRY_LINK([
4449         #include <stdio.h>
4450         #include <math.h>
4451         ],
4452         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
4453         [cf_cv_need_libm=no],
4454         [cf_cv_need_libm=yes])])
4455 if test "$cf_cv_need_libm" = yes
4456 then
4457 ifelse($1,,[
4458         CF_ADD_LIB(m)
4459 ],[$1=-lm])
4460 fi
4461 ])
4462 dnl ---------------------------------------------------------------------------
4463 dnl CF_MIXEDCASE_FILENAMES version: 3 updated: 2003/09/20 17:07:55
4464 dnl ----------------------
4465 dnl Check if the file-system supports mixed-case filenames.  If we're able to
4466 dnl create a lowercase name and see it as uppercase, it doesn't support that.
4467 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
4468 [
4469 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
4470 if test "$cross_compiling" = yes ; then
4471         case $target_alias in #(vi
4472         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-mingw32*|*-uwin*) #(vi
4473                 cf_cv_mixedcase=no
4474                 ;;
4475         *)
4476                 cf_cv_mixedcase=yes
4477                 ;;
4478         esac
4479 else
4480         rm -f conftest CONFTEST
4481         echo test >conftest
4482         if test -f CONFTEST ; then
4483                 cf_cv_mixedcase=no
4484         else
4485                 cf_cv_mixedcase=yes
4486         fi
4487         rm -f conftest CONFTEST
4488 fi
4489 ])
4490 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES)
4491 ])dnl
4492 dnl ---------------------------------------------------------------------------
4493 dnl CF_MKSTEMP version: 8 updated: 2012/02/13 20:34:56
4494 dnl ----------
4495 dnl Check for a working mkstemp.  This creates two files, checks that they are
4496 dnl successfully created and distinct (AmigaOS apparently fails on the last).
4497 AC_DEFUN([CF_MKSTEMP],[
4498 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
4499 rm -rf conftest*
4500 AC_TRY_RUN([
4501 #include <sys/types.h>
4502 #include <stdlib.h>
4503 #include <stdio.h>
4504 #include <string.h>
4505 #include <sys/stat.h>
4506 int main()
4507 {
4508         char *tmpl = "conftestXXXXXX";
4509         char name[2][80];
4510         int n;
4511         int result = 0;
4512         int fd;
4513         struct stat sb;
4514
4515         umask(077);
4516         for (n = 0; n < 2; ++n) {
4517                 strcpy(name[n], tmpl);
4518                 if ((fd = mkstemp(name[n])) >= 0) {
4519                         if (!strcmp(name[n], tmpl)
4520                          || stat(name[n], &sb) != 0
4521                          || (sb.st_mode & S_IFMT) != S_IFREG
4522                          || (sb.st_mode & 077) != 0) {
4523                                 result = 1;
4524                         }
4525                         close(fd);
4526                 }
4527         }
4528         if (result == 0
4529          && !strcmp(name[0], name[1]))
4530                 result = 1;
4531         ${cf_cv_main_return:-return}(result);
4532 }
4533 ],[cf_cv_func_mkstemp=yes
4534 ],[cf_cv_func_mkstemp=no
4535 ],[cf_cv_func_mkstemp=maybe])
4536 ])
4537 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
4538         AC_CHECK_FUNC(mkstemp)
4539 fi
4540 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
4541         AC_DEFINE(HAVE_MKSTEMP)
4542 fi
4543 ])dnl
4544 dnl ---------------------------------------------------------------------------
4545 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
4546 dnl ----------
4547 dnl Write a debug message to config.log, along with the line number in the
4548 dnl configure script.
4549 AC_DEFUN([CF_MSG_LOG],[
4550 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
4551 ])dnl
4552 dnl ---------------------------------------------------------------------------
4553 dnl CF_NCURSES_ABI_6 version: 1 updated: 2005/09/17 18:42:49
4554 dnl ----------------
4555 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
4556 dnl warn about this.
4557 AC_DEFUN([CF_NCURSES_ABI_6],[
4558 if test "${with_abi_version+set}" != set; then
4559         case $cf_cv_rel_version in
4560         5.*)
4561                 cf_cv_rel_version=6.0
4562                 cf_cv_abi_version=6
4563                 AC_MSG_WARN(Overriding ABI version to $cf_cv_abi_version)
4564                 ;;
4565         esac
4566 fi
4567 ])dnl
4568 dnl ---------------------------------------------------------------------------
4569 dnl CF_NO_LEAKS_OPTION version: 4 updated: 2006/12/16 14:24:05
4570 dnl ------------------
4571 dnl see CF_WITH_NO_LEAKS
4572 AC_DEFUN([CF_NO_LEAKS_OPTION],[
4573 AC_MSG_CHECKING(if you want to use $1 for testing)
4574 AC_ARG_WITH($1,
4575         [$2],
4576         [AC_DEFINE($3)ifelse([$4],,[
4577          $4
4578 ])
4579         : ${with_cflags:=-g}
4580         : ${with_no_leaks:=yes}
4581          with_$1=yes],
4582         [with_$1=])
4583 AC_MSG_RESULT(${with_$1:-no})
4584
4585 case .$with_cflags in #(vi
4586 .*-g*)
4587         case .$CFLAGS in #(vi
4588         .*-g*) #(vi
4589                 ;;
4590         *)
4591                 CF_ADD_CFLAGS([-g])
4592                 ;;
4593         esac
4594         ;;
4595 esac
4596 ])dnl
4597 dnl ---------------------------------------------------------------------------
4598 dnl CF_NUMBER_SYNTAX version: 1 updated: 2003/09/20 18:12:49
4599 dnl ----------------
4600 dnl Check if the given variable is a number.  If not, report an error.
4601 dnl $1 is the variable
4602 dnl $2 is the message
4603 AC_DEFUN([CF_NUMBER_SYNTAX],[
4604 if test -n "$1" ; then
4605   case $1 in #(vi
4606   [[0-9]]*) #(vi
4607         ;;
4608   *)
4609         AC_MSG_ERROR($2 is not a number: $1)
4610         ;;
4611   esac
4612 else
4613   AC_MSG_ERROR($2 value is empty)
4614 fi
4615 ])dnl
4616 dnl ---------------------------------------------------------------------------
4617 dnl CF_OBJ_SUBDIR version: 4 updated: 2002/02/23 20:38:31
4618 dnl -------------
4619 dnl Compute the object-directory name from the given model name
4620 AC_DEFUN([CF_OBJ_SUBDIR],
4621 [
4622         case $1 in
4623         libtool) $2='obj_lo'  ;;
4624         normal)  $2='objects' ;;
4625         debug)   $2='obj_g' ;;
4626         profile) $2='obj_p' ;;
4627         shared)
4628                 case $cf_cv_system_name in #(vi
4629                 cygwin) #(vi
4630                         $2='objects' ;;
4631                 *)
4632                         $2='obj_s' ;;
4633                 esac
4634         esac
4635 ])dnl
4636 dnl ---------------------------------------------------------------------------
4637 dnl CF_PATHSEP version: 5 updated: 2010/05/26 05:38:42
4638 dnl ----------
4639 dnl Provide a value for the $PATH and similar separator
4640 AC_DEFUN([CF_PATHSEP],
4641 [
4642         case $cf_cv_system_name in
4643         os2*)   PATH_SEPARATOR=';'  ;;
4644         *)      PATH_SEPARATOR=':'  ;;
4645         esac
4646 ifelse([$1],,,[$1=$PATH_SEPARATOR])
4647         AC_SUBST(PATH_SEPARATOR)
4648 ])dnl
4649 dnl ---------------------------------------------------------------------------
4650 dnl CF_PATH_SYNTAX version: 13 updated: 2010/05/26 05:38:42
4651 dnl --------------
4652 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
4653 dnl begins with one of the prefix/exec_prefix variables, and then again if the
4654 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
4655 dnl delayed evaluation of those symbols.
4656 AC_DEFUN([CF_PATH_SYNTAX],[
4657 if test "x$prefix" != xNONE; then
4658   cf_path_syntax="$prefix"
4659 else
4660   cf_path_syntax="$ac_default_prefix"
4661 fi
4662
4663 case ".[$]$1" in #(vi
4664 .\[$]\(*\)*|.\'*\'*) #(vi
4665   ;;
4666 ..|./*|.\\*) #(vi
4667   ;;
4668 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
4669   ;;
4670 .\[$]{*prefix}*) #(vi
4671   eval $1="[$]$1"
4672   case ".[$]$1" in #(vi
4673   .NONE/*)
4674     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4675     ;;
4676   esac
4677   ;; #(vi
4678 .no|.NONE/*)
4679   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4680   ;;
4681 *)
4682   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
4683   ;;
4684 esac
4685 ])dnl
4686 dnl ---------------------------------------------------------------------------
4687 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
4688 dnl -------------
4689 dnl Check for the package-config program, unless disabled by command-line.
4690 AC_DEFUN([CF_PKG_CONFIG],
4691 [
4692 AC_MSG_CHECKING(if you want to use pkg-config)
4693 AC_ARG_WITH(pkg-config,
4694         [  --with-pkg-config{=path} enable/disable use of pkg-config],
4695         [cf_pkg_config=$withval],
4696         [cf_pkg_config=yes])
4697 AC_MSG_RESULT($cf_pkg_config)
4698
4699 case $cf_pkg_config in #(vi
4700 no) #(vi
4701         PKG_CONFIG=none
4702         ;;
4703 yes) #(vi
4704         CF_ACVERSION_CHECK(2.52,
4705                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
4706                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
4707         ;;
4708 *)
4709         PKG_CONFIG=$withval
4710         ;;
4711 esac
4712
4713 test -z "$PKG_CONFIG" && PKG_CONFIG=none
4714 if test "$PKG_CONFIG" != none ; then
4715         CF_PATH_SYNTAX(PKG_CONFIG)
4716 fi
4717
4718 AC_SUBST(PKG_CONFIG)
4719 ])dnl
4720 dnl ---------------------------------------------------------------------------
4721 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
4722 dnl -----------------
4723 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
4724 dnl
4725 dnl     POSIX.1-1990                            _POSIX_SOURCE
4726 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
4727 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
4728 dnl             Bindings Option
4729 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
4730 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
4731 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
4732 dnl
4733 dnl Parameters:
4734 dnl     $1 is the nominal value for _POSIX_C_SOURCE
4735 AC_DEFUN([CF_POSIX_C_SOURCE],
4736 [
4737 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
4738
4739 cf_save_CFLAGS="$CFLAGS"
4740 cf_save_CPPFLAGS="$CPPFLAGS"
4741
4742 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
4743 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
4744
4745 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
4746         CF_MSG_LOG(if the symbol is already defined go no further)
4747         AC_TRY_COMPILE([#include <sys/types.h>],[
4748 #ifndef _POSIX_C_SOURCE
4749 make an error
4750 #endif],
4751         [cf_cv_posix_c_source=no],
4752         [cf_want_posix_source=no
4753          case .$cf_POSIX_C_SOURCE in #(vi
4754          .[[12]]??*) #(vi
4755                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4756                 ;;
4757          .2) #(vi
4758                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4759                 cf_want_posix_source=yes
4760                 ;;
4761          .*)
4762                 cf_want_posix_source=yes
4763                 ;;
4764          esac
4765          if test "$cf_want_posix_source" = yes ; then
4766                 AC_TRY_COMPILE([#include <sys/types.h>],[
4767 #ifdef _POSIX_SOURCE
4768 make an error
4769 #endif],[],
4770                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
4771          fi
4772          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
4773          CFLAGS="$cf_trim_CFLAGS"
4774          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
4775          CF_MSG_LOG(if the second compile does not leave our definition intact error)
4776          AC_TRY_COMPILE([#include <sys/types.h>],[
4777 #ifndef _POSIX_C_SOURCE
4778 make an error
4779 #endif],,
4780          [cf_cv_posix_c_source=no])
4781          CFLAGS="$cf_save_CFLAGS"
4782          CPPFLAGS="$cf_save_CPPFLAGS"
4783         ])
4784 ])
4785
4786 if test "$cf_cv_posix_c_source" != no ; then
4787         CFLAGS="$cf_trim_CFLAGS"
4788         CPPFLAGS="$cf_trim_CPPFLAGS"
4789         CF_ADD_CFLAGS($cf_cv_posix_c_source)
4790 fi
4791
4792 ])dnl
4793 dnl ---------------------------------------------------------------------------
4794 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
4795 dnl ------------
4796 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
4797 dnl
4798 dnl $1 = symbol to test
4799 dnl $2 = value (if any) to use for a predefinition
4800 AC_DEFUN([CF_PREDEFINE],
4801 [
4802 AC_MSG_CHECKING(if we must define $1)
4803 AC_TRY_COMPILE([#include <sys/types.h>
4804 ],[
4805 #ifndef $1
4806 make an error
4807 #endif],[cf_result=no],[cf_result=yes])
4808 AC_MSG_RESULT($cf_result)
4809
4810 if test "$cf_result" = yes ; then
4811         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
4812 elif test "x$2" != "x" ; then
4813         AC_MSG_CHECKING(checking for compatible value versus $2)
4814         AC_TRY_COMPILE([#include <sys/types.h>
4815 ],[
4816 #if $1-$2 < 0
4817 make an error
4818 #endif],[cf_result=yes],[cf_result=no])
4819         AC_MSG_RESULT($cf_result)
4820         if test "$cf_result" = no ; then
4821                 # perhaps we can override it - try...
4822                 CPPFLAGS="$CPPFLAGS -D$1=$2"
4823         fi
4824 fi
4825 ])dnl
4826 dnl ---------------------------------------------------------------------------
4827 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
4828 dnl ------------
4829 dnl Append definitions and rules for the given programs to the subdirectory
4830 dnl Makefiles, and the recursion rule for the top-level Makefile.
4831 dnl
4832 dnl parameters
4833 dnl     $1 = script to run
4834 dnl     $2 = list of subdirectories
4835 dnl
4836 dnl variables
4837 dnl     $AWK
4838 AC_DEFUN([CF_PRG_RULES],
4839 [
4840 for cf_dir in $2
4841 do
4842         if test ! -d $srcdir/$cf_dir; then
4843                 continue
4844         elif test -f $srcdir/$cf_dir/programs; then
4845                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
4846         fi
4847 done
4848
4849 ])dnl
4850 dnl ---------------------------------------------------------------------------
4851 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
4852 dnl ----------
4853 dnl Check for archiver "ar".
4854 AC_DEFUN([CF_PROG_AR],[
4855 AC_CHECK_TOOL(AR, ar, ar)
4856 ])
4857 dnl ---------------------------------------------------------------------------
4858 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
4859 dnl -----------
4860 dnl Check for awk, ensure that the check found something.
4861 AC_DEFUN([CF_PROG_AWK],
4862 [
4863 AC_PROG_AWK
4864 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
4865 ])dnl
4866 dnl ---------------------------------------------------------------------------
4867 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
4868 dnl --------------
4869 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
4870 dnl the output file can be renamed, and allows for a shell variable that can
4871 dnl be used later.  The parameter is either CC or CXX.  The result is the
4872 dnl cache variable:
4873 dnl     $cf_cv_prog_CC_c_o
4874 dnl     $cf_cv_prog_CXX_c_o
4875 AC_DEFUN([CF_PROG_CC_C_O],
4876 [AC_REQUIRE([AC_PROG_CC])dnl
4877 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
4878 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
4879 [
4880 cat > conftest.$ac_ext <<CF_EOF
4881 #include <stdio.h>
4882 int main()
4883 {
4884         ${cf_cv_main_return:-return}(0);
4885 }
4886 CF_EOF
4887 # We do the test twice because some compilers refuse to overwrite an
4888 # existing .o file with -o, though they will create one.
4889 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
4890 if AC_TRY_EVAL(ac_try) &&
4891   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
4892 then
4893   eval cf_cv_prog_$1_c_o=yes
4894 else
4895   eval cf_cv_prog_$1_c_o=no
4896 fi
4897 rm -rf conftest*
4898 ])dnl
4899 if test $cf_cv_prog_$1_c_o = yes; then
4900   AC_MSG_RESULT([yes])
4901 else
4902   AC_MSG_RESULT([no])
4903 fi
4904 ])dnl
4905 dnl ---------------------------------------------------------------------------
4906 dnl CF_PROG_CC_U_D version: 1 updated: 2005/07/14 16:59:30
4907 dnl --------------
4908 dnl Check if C (preprocessor) -U and -D options are processed in the order
4909 dnl given rather than by type of option.  Some compilers insist on apply all
4910 dnl of the -U options after all of the -D options.  Others allow mixing them,
4911 dnl and may predefine symbols that conflict with those we define.
4912 AC_DEFUN([CF_PROG_CC_U_D],
4913 [
4914 AC_CACHE_CHECK(if $CC -U and -D options work together,cf_cv_cc_u_d_options,[
4915         cf_save_CPPFLAGS="$CPPFLAGS"
4916         CPPFLAGS="-UU_D_OPTIONS -DU_D_OPTIONS -DD_U_OPTIONS -UD_U_OPTIONS"
4917         AC_TRY_COMPILE([],[
4918 #ifndef U_D_OPTIONS
4919 make an undefined-error
4920 #endif
4921 #ifdef  D_U_OPTIONS
4922 make a defined-error
4923 #endif
4924         ],[
4925         cf_cv_cc_u_d_options=yes],[
4926         cf_cv_cc_u_d_options=no])
4927         CPPFLAGS="$cf_save_CPPFLAGS"
4928 ])
4929 ])dnl
4930 dnl ---------------------------------------------------------------------------
4931 dnl CF_PROG_EGREP version: 1 updated: 2006/09/16 11:40:59
4932 dnl -------------
4933 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
4934 dnl This macro adds a check to ensure the script found something.
4935 AC_DEFUN([CF_PROG_EGREP],
4936 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
4937    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
4938     then ac_cv_prog_egrep='grep -E'
4939     else ac_cv_prog_egrep='egrep'
4940     fi])
4941  EGREP=$ac_cv_prog_egrep
4942  AC_SUBST([EGREP])
4943 test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
4944 ])dnl
4945 dnl ---------------------------------------------------------------------------
4946 dnl CF_PROG_EXT version: 10 updated: 2004/01/03 19:28:18
4947 dnl -----------
4948 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
4949 AC_DEFUN([CF_PROG_EXT],
4950 [
4951 AC_REQUIRE([CF_CHECK_CACHE])
4952 case $cf_cv_system_name in
4953 os2*)
4954     CFLAGS="$CFLAGS -Zmt"
4955     CPPFLAGS="$CPPFLAGS -D__ST_MT_ERRNO__"
4956     CXXFLAGS="$CXXFLAGS -Zmt"
4957     # autoconf's macro sets -Zexe and suffix both, which conflict:w
4958     LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
4959     ac_cv_exeext=.exe
4960     ;;
4961 esac
4962
4963 AC_EXEEXT
4964 AC_OBJEXT
4965
4966 PROG_EXT="$EXEEXT"
4967 AC_SUBST(PROG_EXT)
4968 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT")
4969 ])dnl
4970 dnl ---------------------------------------------------------------------------
4971 dnl CF_PROG_GNAT version: 2 updated: 2011/10/22 14:01:47
4972 dnl ------------
4973 dnl Check for gnatmake, ensure that it is complete.
4974 AC_DEFUN([CF_PROG_GNAT],[
4975 cf_ada_make=gnatmake
4976 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
4977 if test "$ac_cv_prog_gnat_exists" = no; then
4978    cf_ada_make=
4979    cf_cv_prog_gnat_correct=no
4980 else
4981    CF_GNAT_VERSION
4982    AC_CHECK_PROG(M4_exists, m4, yes, no)
4983    if test "$ac_cv_prog_M4_exists" = no; then
4984       cf_cv_prog_gnat_correct=no
4985       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
4986    fi
4987    if test "$cf_cv_prog_gnat_correct" = yes; then
4988       AC_MSG_CHECKING(if GNAT works)
4989       CF_GNAT_TRY_RUN([procedure conftest;],
4990 [with Text_IO;
4991 with GNAT.OS_Lib;
4992 procedure conftest is
4993 begin
4994    Text_IO.Put ("Hello World");
4995    Text_IO.New_Line;
4996    GNAT.OS_Lib.OS_Exit (0);
4997 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
4998       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
4999    fi
5000 fi
5001
5002 AC_SUBST(cf_ada_make)
5003 ])dnl
5004 dnl ---------------------------------------------------------------------------
5005 dnl CF_PROG_INSTALL version: 5 updated: 2002/12/21 22:46:07
5006 dnl ---------------
5007 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
5008 dnl misc/tabset install won't work properly.  Usually this happens only when
5009 dnl using the fallback mkinstalldirs script
5010 AC_DEFUN([CF_PROG_INSTALL],
5011 [AC_PROG_INSTALL
5012 case $INSTALL in
5013 /*)
5014   ;;
5015 *)
5016   CF_DIRNAME(cf_dir,$INSTALL)
5017   test -z "$cf_dir" && cf_dir=.
5018   INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
5019   ;;
5020 esac
5021 ])dnl
5022 dnl ---------------------------------------------------------------------------
5023 dnl CF_PROG_LDCONFIG version: 3 updated: 2011/06/04 20:09:13
5024 dnl ----------------
5025 dnl Check for ldconfig, needed to fixup shared libraries that would be built
5026 dnl and then used in the install.
5027 AC_DEFUN([CF_PROG_LDCONFIG],[
5028 if test "$cross_compiling" = yes ; then
5029   LDCONFIG=:
5030 else
5031 case "$cf_cv_system_name" in #(vi
5032 dragonfly*|mirbsd*|freebsd*) #(vi
5033   test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
5034   ;;
5035 *) LDPATH=$PATH:/sbin:/usr/sbin
5036   AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
5037   ;;
5038 esac
5039 fi
5040 AC_SUBST(LDCONFIG)
5041 ])dnl
5042 dnl ---------------------------------------------------------------------------
5043 dnl CF_PROG_LINT version: 2 updated: 2009/08/12 04:43:14
5044 dnl ------------
5045 AC_DEFUN([CF_PROG_LINT],
5046 [
5047 AC_CHECK_PROGS(LINT, tdlint lint alint splint lclint)
5048 AC_SUBST(LINT_OPTS)
5049 ])dnl
5050 dnl ---------------------------------------------------------------------------
5051 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
5052 dnl ------------
5053 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
5054 dnl option if it is supported.
5055 AC_DEFUN([CF_PROG_LN_S],[
5056 AC_PROG_LN_S
5057 AC_MSG_CHECKING(if $LN_S -f options work)
5058
5059 rm -f conf$$.src conf$$dst
5060 echo >conf$$.dst
5061 echo first >conf$$.src
5062 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
5063         cf_prog_ln_sf=yes
5064 else
5065         cf_prog_ln_sf=no
5066 fi
5067 rm -f conf$$.dst conf$$src
5068 AC_MSG_RESULT($cf_prog_ln_sf)
5069
5070 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
5071 ])dnl
5072 dnl ---------------------------------------------------------------------------
5073 dnl CF_REGEX version: 9 updated: 2012/01/07 15:08:24
5074 dnl --------
5075 dnl Attempt to determine if we've got one of the flavors of regular-expression
5076 dnl code that we can support.
5077 AC_DEFUN([CF_REGEX],
5078 [
5079
5080 cf_regex_func=no
5081
5082 cf_regex_libs="regex re"
5083 case $host_os in #(vi
5084 mingw*)
5085         cf_regex_libs="gnurx $cf_regex_libs"
5086         ;;
5087 esac
5088
5089 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
5090         for cf_regex_lib in $cf_regex_libs
5091         do
5092                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
5093                                 CF_ADD_LIB($cf_regex_lib)
5094                                 cf_regex_func=regcomp
5095                                 break])
5096         done
5097 ])
5098
5099 if test "$cf_regex_func" = no ; then
5100         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
5101                 AC_CHECK_LIB(gen,compile,[
5102                                 CF_ADD_LIB(gen)
5103                                 cf_regex_func=compile])])
5104 fi
5105
5106 if test "$cf_regex_func" = no ; then
5107         AC_MSG_WARN(cannot find regular expression library)
5108 fi
5109
5110 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
5111
5112 cf_cv_regex_hdrs=no
5113 case $cf_regex_func in #(vi
5114 compile) #(vi
5115         for cf_regex_hdr in regexp.h regexpr.h
5116         do
5117                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
5118                         char *p = compile("", "", "", 0);
5119                         int x = step("", "");
5120                 ],[
5121                         cf_cv_regex_hdrs=$cf_regex_hdr
5122                         break
5123                 ])
5124         done
5125         ;;
5126 *)
5127         for cf_regex_hdr in regex.h
5128         do
5129                 AC_TRY_LINK([#include <sys/types.h>
5130 #include <$cf_regex_hdr>],[
5131                         regex_t *p;
5132                         int x = regcomp(p, "", 0);
5133                         int y = regexec(p, "", 0, 0, 0);
5134                         regfree(p);
5135                 ],[
5136                         cf_cv_regex_hdrs=$cf_regex_hdr
5137                         break
5138                 ])
5139         done
5140         ;;
5141 esac
5142
5143 ])
5144
5145 case $cf_cv_regex_hdrs in #(vi
5146     no)        AC_MSG_WARN(no regular expression header found) ;; #(vi
5147     regex.h)   AC_DEFINE(HAVE_REGEX_H_FUNCS) ;; #(vi
5148     regexp.h)  AC_DEFINE(HAVE_REGEXP_H_FUNCS) ;; #(vi
5149     regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS) ;;
5150 esac
5151 ])dnl
5152 dnl ---------------------------------------------------------------------------
5153 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
5154 dnl ----------------
5155 dnl Remove all -U and -D options that refer to the given symbol from a list
5156 dnl of C compiler options.  This works around the problem that not all
5157 dnl compilers process -U and -D options from left-to-right, so a -U option
5158 dnl cannot be used to cancel the effect of a preceding -D option.
5159 dnl
5160 dnl $1 = target (which could be the same as the source variable)
5161 dnl $2 = source (including '$')
5162 dnl $3 = symbol to remove
5163 define([CF_REMOVE_DEFINE],
5164 [
5165 $1=`echo "$2" | \
5166         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
5167                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
5168 ])dnl
5169 dnl ---------------------------------------------------------------------------
5170 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
5171 dnl -------------
5172 dnl Remove the given library from the symbol
5173 dnl
5174 dnl $1 = target (which could be the same as the source variable)
5175 dnl $2 = source (including '$')
5176 dnl $3 = library to remove
5177 define([CF_REMOVE_LIB],
5178 [
5179 # remove $3 library from $2
5180 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5181 ])dnl
5182 dnl ---------------------------------------------------------------------------
5183 dnl CF_RPATH_HACK version: 9 updated: 2011/02/13 13:31:33
5184 dnl -------------
5185 AC_DEFUN([CF_RPATH_HACK],
5186 [
5187 AC_REQUIRE([CF_LD_RPATH_OPT])
5188 AC_MSG_CHECKING(for updated LDFLAGS)
5189 if test -n "$LD_RPATH_OPT" ; then
5190         AC_MSG_RESULT(maybe)
5191
5192         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5193         cf_rpath_list="/usr/lib /lib"
5194         if test "$cf_ldd_prog" != no
5195         then
5196                 cf_rpath_oops=
5197
5198 AC_TRY_LINK([#include <stdio.h>],
5199                 [printf("Hello");],
5200                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort -u`
5201                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort -u`])
5202
5203                 # If we passed the link-test, but get a "not found" on a given library,
5204                 # this could be due to inept reconfiguration of gcc to make it only
5205                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
5206                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
5207                 # /usr/local libraries.
5208                 if test -n "$cf_rpath_oops"
5209                 then
5210                         for cf_rpath_src in $cf_rpath_oops
5211                         do
5212                                 for cf_rpath_dir in \
5213                                         /usr/local \
5214                                         /usr/pkg \
5215                                         /opt/sfw
5216                                 do
5217                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
5218                                         then
5219                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
5220                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
5221                                                 break
5222                                         fi
5223                                 done
5224                         done
5225                 fi
5226         fi
5227
5228         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5229
5230         CF_RPATH_HACK_2(LDFLAGS)
5231         CF_RPATH_HACK_2(LIBS)
5232
5233         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5234 fi
5235 AC_SUBST(EXTRA_LDFLAGS)
5236 ])dnl
5237 dnl ---------------------------------------------------------------------------
5238 dnl CF_RPATH_HACK_2 version: 6 updated: 2010/04/17 16:31:24
5239 dnl ---------------
5240 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
5241 dnl EXTRA_LDFLAGS for each -L option found.
5242 dnl
5243 dnl $cf_rpath_list contains a list of directories to ignore.
5244 dnl
5245 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
5246 dnl      but LIBS often has misplaced -L options.
5247 AC_DEFUN([CF_RPATH_HACK_2],
5248 [
5249 CF_VERBOSE(...checking $1 [$]$1)
5250
5251 cf_rpath_dst=
5252 for cf_rpath_src in [$]$1
5253 do
5254         case $cf_rpath_src in #(vi
5255         -L*) #(vi
5256
5257                 # check if this refers to a directory which we will ignore
5258                 cf_rpath_skip=no
5259                 if test -n "$cf_rpath_list"
5260                 then
5261                         for cf_rpath_item in $cf_rpath_list
5262                         do
5263                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
5264                                 then
5265                                         cf_rpath_skip=yes
5266                                         break
5267                                 fi
5268                         done
5269                 fi
5270
5271                 if test "$cf_rpath_skip" = no
5272                 then
5273                         # transform the option
5274                         if test "$LD_RPATH_OPT" = "-R " ; then
5275                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
5276                         else
5277                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
5278                         fi
5279
5280                         # if we have not already added this, add it now
5281                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
5282                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
5283                         then
5284                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
5285                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
5286                         fi
5287                 fi
5288                 ;;
5289         esac
5290         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
5291 done
5292 $1=$cf_rpath_dst
5293
5294 CF_VERBOSE(...checked $1 [$]$1)
5295 AC_SUBST(EXTRA_LDFLAGS)
5296 ])dnl
5297 dnl ---------------------------------------------------------------------------
5298 dnl CF_SHARED_OPTS version: 70 updated: 2012/02/25 15:20:07
5299 dnl --------------
5300 dnl --------------
5301 dnl Attempt to determine the appropriate CC/LD options for creating a shared
5302 dnl library.
5303 dnl
5304 dnl Note: ${LOCAL_LDFLAGS} is used to link executables that will run within the
5305 dnl build-tree, i.e., by making use of the libraries that are compiled in ../lib
5306 dnl We avoid compiling-in a ../lib path for the shared library since that can
5307 dnl lead to unexpected results at runtime.
5308 dnl ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared libraries
5309 dnl are compiled in ../../lib
5310 dnl
5311 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
5312 dnl to install symbolic links to the rel/abi versions of shared libraries.
5313 dnl
5314 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
5315 dnl version when making symbolic links.
5316 dnl
5317 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
5318 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
5319 dnl (ex: libncurses.so.<ver>).
5320 dnl
5321 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
5322 AC_DEFUN([CF_SHARED_OPTS],
5323 [
5324         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
5325         AC_REQUIRE([CF_LD_RPATH_OPT])
5326         LOCAL_LDFLAGS=
5327         LOCAL_LDFLAGS2=
5328         LD_SHARED_OPTS=
5329         INSTALL_LIB="-m 644"
5330
5331         cf_cv_do_symlinks=no
5332         cf_ld_rpath_opt=
5333         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
5334
5335         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
5336         AC_ARG_WITH(shlib-version,
5337         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
5338         [test -z "$withval" && withval=auto
5339         case $withval in #(vi
5340         yes) #(vi
5341                 cf_cv_shlib_version=auto
5342                 ;;
5343         rel|abi|auto|no) #(vi
5344                 cf_cv_shlib_version=$withval
5345                 ;;
5346         *)
5347                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
5348                 ;;
5349         esac
5350         ],[cf_cv_shlib_version=auto])
5351         AC_MSG_RESULT($cf_cv_shlib_version)
5352
5353         cf_cv_rm_so_locs=no
5354
5355         # Some less-capable ports of gcc support only -fpic
5356         CC_SHARED_OPTS=
5357         if test "$GCC" = yes
5358         then
5359                 AC_MSG_CHECKING(which $CC option to use)
5360                 cf_save_CFLAGS="$CFLAGS"
5361                 for CC_SHARED_OPTS in -fPIC -fpic ''
5362                 do
5363                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
5364                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
5365                 done
5366                 AC_MSG_RESULT($CC_SHARED_OPTS)
5367                 CFLAGS="$cf_save_CFLAGS"
5368         fi
5369
5370         cf_cv_shlib_version_infix=no
5371
5372         case $cf_cv_system_name in #(vi
5373         aix4.[3-9]*|aix[[5-7]]*) #(vi
5374                 if test "$GCC" = yes; then
5375                         CC_SHARED_OPTS=
5376                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5377                 else
5378                         # CC_SHARED_OPTS='-qpic=large -G'
5379                         # perhaps "-bM:SRE -bnoentry -bexpall"
5380                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5381                 fi
5382                 ;;
5383         beos*) #(vi
5384                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
5385                 ;;
5386         cygwin*) #(vi
5387                 CC_SHARED_OPTS=
5388                 MK_SHARED_LIB='sh ../mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5389                 cf_cv_shlib_version=cygdll
5390                 cf_cv_shlib_version_infix=cygdll
5391                 cat >mk_shared_lib.sh <<-CF_EOF
5392                 #!/bin/sh
5393                 SHARED_LIB=\[$]1
5394                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5395                 shift
5396                 cat <<-EOF
5397                 Linking shared library
5398                 ** SHARED_LIB \[$]SHARED_LIB
5399                 ** IMPORT_LIB \[$]IMPORT_LIB
5400 EOF
5401                 exec \[$]* -shared -Wl,--out-implib=../lib/\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o ../lib/\[$]{SHARED_LIB}
5402 CF_EOF
5403                 chmod +x mk_shared_lib.sh
5404                 ;;
5405         darwin*) #(vi
5406                 EXTRA_CFLAGS="-no-cpp-precomp"
5407                 CC_SHARED_OPTS="-dynamic"
5408                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
5409                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
5410                 cf_cv_shlib_version_infix=yes
5411                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
5412                         cf_save_LDFLAGS=$LDFLAGS
5413                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5414                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
5415                                 LDFLAGS=$cf_save_LDFLAGS])
5416                 if test $cf_cv_ldflags_search_paths_first = yes; then
5417                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5418                 fi
5419                 ;;
5420         hpux*) #(vi
5421                 # (tested with gcc 2.7.2 -- I don't have c89)
5422                 if test "$GCC" = yes; then
5423                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
5424                 else
5425                         CC_SHARED_OPTS='+Z'
5426                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
5427                 fi
5428                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
5429                 # HP-UX shared libraries must be executable, and should be
5430                 # readonly to exploit a quirk in the memory manager.
5431                 INSTALL_LIB="-m 555"
5432                 ;;
5433         interix*)
5434                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5435                 if test "$cf_cv_shlib_version" = rel; then
5436                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
5437                 else
5438                         cf_shared_soname='`basename $@`'
5439                 fi
5440                 CC_SHARED_OPTS=
5441                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
5442                 ;;
5443         irix*) #(vi
5444                 if test "$cf_cv_enable_rpath" = yes ; then
5445                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5446                 fi
5447                 # tested with IRIX 5.2 and 'cc'.
5448                 if test "$GCC" != yes; then
5449                         CC_SHARED_OPTS='-KPIC'
5450                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
5451                 else
5452                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
5453                 fi
5454                 cf_cv_rm_so_locs=yes
5455                 ;;
5456         linux*|gnu*|k*bsd*-gnu) #(vi
5457                 if test "$DFT_LWR_MODEL" = "shared" ; then
5458                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5459                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5460                 fi
5461                 if test "$cf_cv_enable_rpath" = yes ; then
5462                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5463                 fi
5464                 CF_SHARED_SONAME
5465                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5466                 ;;
5467         mingw*) #(vi
5468                 cf_cv_shlib_version=mingw
5469                 cf_cv_shlib_version_infix=mingw
5470                 CC_SHARED_OPTS=
5471                 MK_SHARED_LIB='sh ../mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5472                 #MK_SHARED_LIB='${CC} ${CFLAGS} -mdll -Wl,-soname,'$cf_cv_shared_soname',-stats -o $[@]'
5473                 #MK_SHARED_LIB='${DLLTOOL} --export-all-symbols --output-exp --output-lib $[@]'
5474                 cat >mk_shared_lib.sh <<-CF_EOF
5475                 #!/bin/sh
5476                 SHARED_LIB=\[$]1
5477                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5478                 shift
5479                 cat <<-EOF
5480                 Linking shared library
5481                 ** SHARED_LIB \[$]SHARED_LIB
5482                 ** IMPORT_LIB \[$]IMPORT_LIB
5483 EOF
5484                 exec \[$]* -shared -Wl,--out-implib=../lib/\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o ../lib/\[$]{SHARED_LIB}
5485 CF_EOF
5486                 chmod +x mk_shared_lib.sh
5487                 ;;
5488         openbsd[[2-9]].*|mirbsd*) #(vi
5489                 if test "$DFT_LWR_MODEL" = "shared" ; then
5490                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5491                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5492                 fi
5493                 if test "$cf_cv_enable_rpath" = yes ; then
5494                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5495                 fi
5496                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5497                 CF_SHARED_SONAME
5498                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5499                 ;;
5500         nto-qnx*|openbsd*|freebsd[[12]].*) #(vi
5501                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5502                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
5503                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5504                 ;;
5505         dragonfly*|freebsd*) #(vi
5506                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5507                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5508                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5509                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
5510                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5511                 fi
5512                 CF_SHARED_SONAME
5513                 MK_SHARED_LIB='${LD} -shared -Bshareable -soname=`basename $[@]` -o $[@]'
5514                 ;;
5515         netbsd*) #(vi
5516                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5517                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5518                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5519                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5520                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5521                         if test "$cf_cv_shlib_version" = auto; then
5522                         if test -f /usr/libexec/ld.elf_so; then
5523                                 cf_cv_shlib_version=abi
5524                         else
5525                                 cf_cv_shlib_version=rel
5526                         fi
5527                         fi
5528                         CF_SHARED_SONAME
5529                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
5530                 else
5531                         MK_SHARED_LIB='${LD} -shared -Bshareable -o $[@]'
5532                 fi
5533                 ;;
5534         osf*|mls+*) #(vi
5535                 # tested with OSF/1 V3.2 and 'cc'
5536                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
5537                 # link with shared libs).
5538                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
5539                 case $host_os in #(vi
5540                 osf4*)
5541                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
5542                         ;;
5543                 esac
5544                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
5545                 if test "$DFT_LWR_MODEL" = "shared" ; then
5546                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5547                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5548                 fi
5549                 cf_cv_rm_so_locs=yes
5550                 ;;
5551         sco3.2v5*)  # (also uw2* and UW7: hops 13-Apr-98
5552                 # tested with osr5.0.5
5553                 if test "$GCC" != yes; then
5554                         CC_SHARED_OPTS='-belf -KPIC'
5555                 fi
5556                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
5557                 if test "$cf_cv_enable_rpath" = yes ; then
5558                         # only way is to set LD_RUN_PATH but no switch for it
5559                         RUN_PATH=$libdir
5560                 fi
5561                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5562                 LINK_PROGS='LD_RUN_PATH=${libdir}'
5563                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
5564                 ;;
5565         sunos4*) #(vi
5566                 # tested with SunOS 4.1.1 and gcc 2.7.0
5567                 if test "$GCC" != yes; then
5568                         CC_SHARED_OPTS='-KPIC'
5569                 fi
5570                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
5571                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5572                 ;;
5573         solaris2*) #(vi
5574                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
5575                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
5576                 if test "$DFT_LWR_MODEL" = "shared" ; then
5577                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
5578                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5579                 fi
5580                 if test "$cf_cv_enable_rpath" = yes ; then
5581                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
5582                 fi
5583                 CF_SHARED_SONAME
5584                 if test "$GCC" != yes; then
5585                         cf_save_CFLAGS="$CFLAGS"
5586                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
5587                         do
5588                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
5589                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
5590                         done
5591                         CFLAGS="$cf_save_CFLAGS"
5592                         CC_SHARED_OPTS=$cf_shared_opts
5593                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5594                 else
5595                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5596                 fi
5597                 ;;
5598         sysv5uw7*|unix_sv*) #(vi
5599                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
5600                 if test "$GCC" != yes; then
5601                         CC_SHARED_OPTS='-KPIC'
5602                 fi
5603                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
5604                 ;;
5605         *)
5606                 CC_SHARED_OPTS='unknown'
5607                 MK_SHARED_LIB='echo unknown'
5608                 ;;
5609         esac
5610
5611         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
5612         case "$cf_cv_shlib_version" in #(vi
5613         rel|abi)
5614                 case "$MK_SHARED_LIB" in #(vi
5615                 *'-o $[@]') #(vi
5616                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
5617                         ;;
5618                 *)
5619                         AC_MSG_WARN(ignored --with-shlib-version)
5620                         ;;
5621                 esac
5622                 ;;
5623         esac
5624
5625         # RPATH_LIST is a colon-separated list of directories
5626         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
5627         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
5628
5629         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
5630         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
5631
5632         AC_SUBST(CC_SHARED_OPTS)
5633         AC_SUBST(LD_RPATH_OPT)
5634         AC_SUBST(LD_SHARED_OPTS)
5635         AC_SUBST(MK_SHARED_LIB)
5636         AC_SUBST(LINK_PROGS)
5637         AC_SUBST(LINK_TESTS)
5638         AC_SUBST(EXTRA_LDFLAGS)
5639         AC_SUBST(LOCAL_LDFLAGS)
5640         AC_SUBST(LOCAL_LDFLAGS2)
5641         AC_SUBST(INSTALL_LIB)
5642         AC_SUBST(RPATH_LIST)
5643 ])dnl
5644 dnl ---------------------------------------------------------------------------
5645 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
5646 dnl ----------------
5647 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
5648 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
5649 dnl option.
5650 dnl
5651 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
5652 dnl If missing, use "rel".
5653 define([CF_SHARED_SONAME],
5654 [
5655         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
5656         if test "$cf_cv_shlib_version" = rel; then
5657                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
5658         else
5659                 cf_cv_shared_soname='`basename $[@]`'
5660         fi
5661 ])
5662 dnl ---------------------------------------------------------------------------
5663 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
5664 dnl -----------
5665 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
5666 dnl programs need this test).
5667 dnl
5668 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
5669 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
5670 dnl winsize declaration is left alone - we may revisit this if Apple choose to
5671 dnl break that part of the interface as well.
5672 AC_DEFUN([CF_SIGWINCH],
5673 [
5674 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
5675         AC_TRY_COMPILE([
5676 #include <sys/types.h>
5677 #include <sys/signal.h>
5678 ],[int x = SIGWINCH],
5679         [cf_cv_define_sigwinch=yes],
5680         [AC_TRY_COMPILE([
5681 #undef _XOPEN_SOURCE
5682 #undef _POSIX_SOURCE
5683 #undef _POSIX_C_SOURCE
5684 #include <sys/types.h>
5685 #include <sys/signal.h>
5686 ],[int x = SIGWINCH],
5687         [cf_cv_define_sigwinch=maybe],
5688         [cf_cv_define_sigwinch=no])
5689 ])
5690 ])
5691
5692 if test "$cf_cv_define_sigwinch" = maybe ; then
5693 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
5694 cf_cv_fixup_sigwinch=unknown
5695 cf_sigwinch=32
5696 while test $cf_sigwinch != 1
5697 do
5698         AC_TRY_COMPILE([
5699 #undef _XOPEN_SOURCE
5700 #undef _POSIX_SOURCE
5701 #undef _POSIX_C_SOURCE
5702 #include <sys/types.h>
5703 #include <sys/signal.h>
5704 ],[
5705 #if SIGWINCH != $cf_sigwinch
5706 make an error
5707 #endif
5708 int x = SIGWINCH],
5709         [cf_cv_fixup_sigwinch=$cf_sigwinch
5710          break])
5711
5712 cf_sigwinch=`expr $cf_sigwinch - 1`
5713 done
5714 ])
5715
5716         if test "$cf_cv_fixup_sigwinch" != unknown ; then
5717                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
5718         fi
5719 fi
5720 ])dnl
5721 dnl ---------------------------------------------------------------------------
5722 dnl CF_SIG_ATOMIC_T version: 2 updated: 2005/09/18 17:27:12
5723 dnl ---------------
5724 dnl signal handler, but there are some gcc depedencies in that recommendation.
5725 dnl Try anyway.
5726 AC_DEFUN([CF_SIG_ATOMIC_T],
5727 [
5728 AC_MSG_CHECKING(for signal global datatype)
5729 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
5730         for cf_type in \
5731                 "volatile sig_atomic_t" \
5732                 "sig_atomic_t" \
5733                 "int"
5734         do
5735         AC_TRY_COMPILE([
5736 #include <sys/types.h>
5737 #include <signal.h>
5738 #include <stdio.h>
5739
5740 extern $cf_type x;
5741 $cf_type x;
5742 static void handler(int sig)
5743 {
5744         x = 5;
5745 }],
5746                 [signal(SIGINT, handler);
5747                  x = 1],
5748                 [cf_cv_sig_atomic_t=$cf_type],
5749                 [cf_cv_sig_atomic_t=no])
5750                 test "$cf_cv_sig_atomic_t" != no && break
5751         done
5752         ])
5753 AC_MSG_RESULT($cf_cv_sig_atomic_t)
5754 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t)
5755 ])dnl
5756 dnl ---------------------------------------------------------------------------
5757 dnl CF_SIZECHANGE version: 8 updated: 2000/11/04 12:22:16
5758 dnl -------------
5759 dnl Check for definitions & structures needed for window size-changing
5760 dnl FIXME: check that this works with "snake" (HP-UX 10.x)
5761 AC_DEFUN([CF_SIZECHANGE],
5762 [
5763 AC_REQUIRE([CF_STRUCT_TERMIOS])
5764 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
5765     cf_cv_sizechange=unknown
5766     cf_save_CPPFLAGS="$CPPFLAGS"
5767
5768 for cf_opts in "" "NEED_PTEM_H"
5769 do
5770
5771     CPPFLAGS="$cf_save_CPPFLAGS"
5772     test -n "$cf_opts" && CPPFLAGS="$CPPFLAGS -D$cf_opts"
5773     AC_TRY_COMPILE([#include <sys/types.h>
5774 #ifdef HAVE_TERMIOS_H
5775 #include <termios.h>
5776 #else
5777 #ifdef HAVE_TERMIO_H
5778 #include <termio.h>
5779 #endif
5780 #endif
5781 #ifdef NEED_PTEM_H
5782 /* This is a workaround for SCO:  they neglected to define struct winsize in
5783  * termios.h -- it's only in termio.h and ptem.h
5784  */
5785 #include        <sys/stream.h>
5786 #include        <sys/ptem.h>
5787 #endif
5788 #if !defined(sun) || !defined(HAVE_TERMIOS_H)
5789 #include <sys/ioctl.h>
5790 #endif
5791 ],[
5792 #ifdef TIOCGSIZE
5793         struct ttysize win;     /* FIXME: what system is this? */
5794         int y = win.ts_lines;
5795         int x = win.ts_cols;
5796 #else
5797 #ifdef TIOCGWINSZ
5798         struct winsize win;
5799         int y = win.ws_row;
5800         int x = win.ws_col;
5801 #else
5802         no TIOCGSIZE or TIOCGWINSZ
5803 #endif /* TIOCGWINSZ */
5804 #endif /* TIOCGSIZE */
5805         ],
5806         [cf_cv_sizechange=yes],
5807         [cf_cv_sizechange=no])
5808
5809         CPPFLAGS="$cf_save_CPPFLAGS"
5810         if test "$cf_cv_sizechange" = yes ; then
5811                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
5812                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
5813                 break
5814         fi
5815 done
5816 ])
5817 if test "$cf_cv_sizechange" != no ; then
5818         AC_DEFINE(HAVE_SIZECHANGE)
5819         case $cf_cv_sizechange in #(vi
5820         NEED*)
5821                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
5822                 ;;
5823         esac
5824 fi
5825 ])dnl
5826 dnl ---------------------------------------------------------------------------
5827 dnl CF_SRC_MODULES version: 26 updated: 2012/01/07 15:08:24
5828 dnl --------------
5829 dnl For each parameter, test if the source-directory exists, and if it contains
5830 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
5831 dnl use in CF_LIB_RULES.
5832 dnl
5833 dnl This uses the configured value to make the lists SRC_SUBDIRS and
5834 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
5835 AC_DEFUN([CF_SRC_MODULES],
5836 [
5837 AC_MSG_CHECKING(for src modules)
5838
5839 # dependencies and linker-arguments for test-programs
5840 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
5841 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
5842 if test "$DFT_LWR_MODEL" = "libtool"; then
5843         TEST_ARGS="${TEST_DEPS}"
5844         TEST_ARG2="${TEST_DEP2}"
5845 else
5846         TEST_ARGS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
5847         TEST_ARG2="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARG2"
5848 fi
5849
5850 PC_MODULES_TO_MAKE="ncurses${DFT_ARG_SUFFIX}"
5851 cf_cv_src_modules=
5852 for cf_dir in $1
5853 do
5854         if test -f $srcdir/$cf_dir/modules; then
5855
5856                 # We may/may not have tack in the distribution, though the
5857                 # makefile is.
5858                 if test $cf_dir = tack ; then
5859                         if test ! -f $srcdir/${cf_dir}/${cf_dir}.h; then
5860                                 continue
5861                         fi
5862                 fi
5863
5864                 if test -z "$cf_cv_src_modules"; then
5865                         cf_cv_src_modules=$cf_dir
5866                 else
5867                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
5868                 fi
5869
5870                 # Make the ncurses_cfg.h file record the library interface files as
5871                 # well.  These are header files that are the same name as their
5872                 # directory.  Ncurses is the only library that does not follow
5873                 # that pattern.
5874                 if test $cf_dir = tack ; then
5875                         continue
5876                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
5877                         CF_UPPER(cf_have_include,$cf_dir)
5878                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
5879                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
5880                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
5881                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
5882                         if test "$DFT_LWR_MODEL" = "libtool"; then
5883                                 TEST_ARGS="${TEST_DEPS}"
5884                                 TEST_ARG2="${TEST_DEP2}"
5885                         else
5886                                 TEST_ARGS="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARGS"
5887                                 TEST_ARG2="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARG2"
5888                         fi
5889                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${DFT_ARG_SUFFIX}"
5890                 fi
5891         fi
5892 done
5893 AC_MSG_RESULT($cf_cv_src_modules)
5894
5895 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
5896 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
5897
5898 AC_SUBST(TEST_ARGS)
5899 AC_SUBST(TEST_DEPS)
5900
5901 AC_SUBST(TEST_ARG2)
5902 AC_SUBST(TEST_DEP2)
5903
5904 SRC_SUBDIRS=
5905 if test "x$cf_with_manpages" != xno ; then
5906         SRC_SUBDIRS="$SRC_SUBDIRS man"
5907 fi
5908 SRC_SUBDIRS="$SRC_SUBDIRS include"
5909 for cf_dir in $cf_cv_src_modules
5910 do
5911         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
5912 done
5913 if test "x$cf_with_tests" != "xno" ; then
5914         SRC_SUBDIRS="$SRC_SUBDIRS test"
5915 fi
5916 test -z "$MAKE_TERMINFO" && SRC_SUBDIRS="$SRC_SUBDIRS misc"
5917 if test "$cf_with_cxx_binding" != no; then
5918         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${DFT_ARG_SUFFIX}"
5919         SRC_SUBDIRS="$SRC_SUBDIRS c++"
5920 fi
5921
5922 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
5923 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
5924
5925 AC_SUBST(PC_MODULES_TO_MAKE)
5926
5927 ADA_SUBDIRS=
5928 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
5929         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
5930         ADA_SUBDIRS="gen src"
5931         if test "x$cf_with_tests" != "xno" ; then
5932                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
5933         fi
5934 fi
5935
5936 SUB_MAKEFILES=
5937 for cf_dir in $SRC_SUBDIRS
5938 do
5939         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
5940 done
5941
5942 if test -n "$ADA_SUBDIRS"; then
5943         for cf_dir in $ADA_SUBDIRS
5944         do
5945                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
5946         done
5947         AC_SUBST(ADA_SUBDIRS)
5948 fi
5949 ])dnl
5950 dnl ---------------------------------------------------------------------------
5951 dnl CF_STDCPP_LIBRARY version: 7 updated: 2010/05/29 16:31:02
5952 dnl -----------------
5953 dnl Check for -lstdc++, which is GNU's standard C++ library.
5954 AC_DEFUN([CF_STDCPP_LIBRARY],
5955 [
5956 if test -n "$GXX" ; then
5957 case $cf_cv_system_name in #(vi
5958 os2*) #(vi
5959         cf_stdcpp_libname=stdcpp
5960         ;;
5961 *)
5962         cf_stdcpp_libname=stdc++
5963         ;;
5964 esac
5965 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
5966         cf_save="$LIBS"
5967         CF_ADD_LIB($cf_stdcpp_libname)
5968 AC_TRY_LINK([
5969 #include <strstream.h>],[
5970 char buf[80];
5971 strstreambuf foo(buf, sizeof(buf))
5972 ],
5973         [cf_cv_libstdcpp=yes],
5974         [cf_cv_libstdcpp=no])
5975         LIBS="$cf_save"
5976 ])
5977 test "$cf_cv_libstdcpp" = yes && CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS)
5978 fi
5979 ])dnl
5980 dnl ---------------------------------------------------------------------------
5981 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
5982 dnl --------------
5983 dnl     Remove "-g" option from the compiler options
5984 AC_DEFUN([CF_STRIP_G_OPT],
5985 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
5986 dnl ---------------------------------------------------------------------------
5987 dnl CF_STRUCT_SIGACTION version: 4 updated: 2011/04/16 11:52:53
5988 dnl -------------------
5989 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
5990 dnl do this if we've found the sigaction function.
5991 AC_DEFUN([CF_STRUCT_SIGACTION],[
5992 AC_REQUIRE([CF_XOPEN_SOURCE])
5993
5994 if test "$ac_cv_func_sigaction" = yes; then
5995 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
5996 AC_TRY_COMPILE([
5997 #include <sys/types.h>
5998 #include <signal.h>],
5999         [struct sigaction act],
6000         [sigact_bad=no],
6001         [
6002 AC_TRY_COMPILE([
6003 #define _POSIX_SOURCE
6004 #include <sys/types.h>
6005 #include <signal.h>],
6006         [struct sigaction act],
6007         [sigact_bad=yes
6008          AC_DEFINE(_POSIX_SOURCE)],
6009          [sigact_bad=unknown])])
6010 AC_MSG_RESULT($sigact_bad)
6011 fi
6012 ])dnl
6013 dnl ---------------------------------------------------------------------------
6014 dnl CF_STRUCT_TERMIOS version: 6 updated: 2011/04/16 11:52:53
6015 dnl -----------------
6016 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
6017 AC_DEFUN([CF_STRUCT_TERMIOS],[
6018 AC_REQUIRE([CF_XOPEN_SOURCE])
6019
6020 AC_CHECK_HEADERS( \
6021 termio.h \
6022 termios.h \
6023 unistd.h \
6024 )
6025
6026 if test "$ISC" = yes ; then
6027         AC_CHECK_HEADERS( sys/termio.h )
6028 fi
6029 if test "$ac_cv_header_termios_h" = yes ; then
6030         case "$CFLAGS $CPPFLAGS" in
6031         *-D_POSIX_SOURCE*)
6032                 termios_bad=dunno ;;
6033         *)      termios_bad=maybe ;;
6034         esac
6035         if test "$termios_bad" = maybe ; then
6036         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
6037         AC_TRY_COMPILE([#include <termios.h>],
6038                 [struct termios foo; int x = foo.c_iflag],
6039                 termios_bad=no, [
6040                 AC_TRY_COMPILE([
6041 #define _POSIX_SOURCE
6042 #include <termios.h>],
6043                         [struct termios foo; int x = foo.c_iflag],
6044                         termios_bad=unknown,
6045                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE))
6046                         ])
6047         AC_MSG_RESULT($termios_bad)
6048         fi
6049 fi
6050 ])dnl
6051 dnl ---------------------------------------------------------------------------
6052 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
6053 dnl --------------
6054 dnl Construct a search-list for a nonstandard header/lib-file
6055 dnl     $1 = the variable to return as result
6056 dnl     $2 = the package name
6057 dnl     $3 = the subdirectory, e.g., bin, include or lib
6058 AC_DEFUN([CF_SUBDIR_PATH],
6059 [
6060 $1=
6061
6062 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
6063 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
6064 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
6065 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
6066 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
6067 ])dnl
6068 dnl ---------------------------------------------------------------------------
6069 dnl CF_SUBST version: 4 updated: 2006/06/17 12:33:03
6070 dnl --------
6071 dnl     Shorthand macro for substituting things that the user may override
6072 dnl     with an environment variable.
6073 dnl
6074 dnl     $1 = long/descriptive name
6075 dnl     $2 = environment variable
6076 dnl     $3 = default value
6077 AC_DEFUN([CF_SUBST],
6078 [AC_CACHE_VAL(cf_cv_subst_$2,[
6079 AC_MSG_CHECKING(for $1 (symbol $2))
6080 CF_SUBST_IF([-z "[$]$2"], [$2], [$3])
6081 cf_cv_subst_$2=[$]$2
6082 AC_MSG_RESULT([$]$2)
6083 ])
6084 ])dnl
6085 dnl ---------------------------------------------------------------------------
6086 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
6087 dnl -----------
6088 dnl     Shorthand macro for substituting things that the user may override
6089 dnl     with an environment variable.
6090 dnl
6091 dnl     $1 = condition to pass to "test"
6092 dnl     $2 = environment variable
6093 dnl     $3 = value if the test succeeds
6094 dnl     $4 = value if the test fails
6095 AC_DEFUN([CF_SUBST_IF],
6096 [
6097 if test $1 ; then
6098         $2=$3
6099 ifelse($4,,,[else
6100         $2=$4])
6101 fi
6102 AC_SUBST($2)
6103 ])dnl
6104 dnl ---------------------------------------------------------------------------
6105 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
6106 dnl ------------------------
6107 dnl Get the version-number for use in shared-library naming, etc.
6108 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
6109 [
6110 AC_REQUIRE([CF_PROG_EGREP])
6111 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6112 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6113 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6114 cf_cv_abi_version=${NCURSES_MAJOR}
6115 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
6116 dnl Show the computed version, for logging
6117 cf_cv_timestamp=`date`
6118 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
6119 dnl We need these values in the generated headers
6120 AC_SUBST(NCURSES_MAJOR)
6121 AC_SUBST(NCURSES_MINOR)
6122 AC_SUBST(NCURSES_PATCH)
6123 dnl We need these values in the generated makefiles
6124 AC_SUBST(cf_cv_rel_version)
6125 AC_SUBST(cf_cv_abi_version)
6126 AC_SUBST(cf_cv_builtin_bool)
6127 AC_SUBST(cf_cv_header_stdbool_h)
6128 AC_SUBST(cf_cv_type_of_bool)dnl
6129 ])dnl
6130 dnl ---------------------------------------------------------------------------
6131 dnl CF_SYS_TIME_SELECT version: 4 updated: 2000/10/04 09:18:40
6132 dnl ------------------
6133 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
6134 dnl older SCO configurations.
6135 AC_DEFUN([CF_SYS_TIME_SELECT],
6136 [
6137 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
6138 AC_CACHE_VAL(cf_cv_sys_time_select,[
6139 AC_TRY_COMPILE([
6140 #include <sys/types.h>
6141 #ifdef HAVE_SYS_TIME_H
6142 #include <sys/time.h>
6143 #endif
6144 #ifdef HAVE_SYS_SELECT_H
6145 #include <sys/select.h>
6146 #endif
6147 ],[],[cf_cv_sys_time_select=yes],
6148      [cf_cv_sys_time_select=no])
6149      ])
6150 AC_MSG_RESULT($cf_cv_sys_time_select)
6151 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT)
6152 ])dnl
6153 dnl ---------------------------------------------------------------------------
6154 dnl CF_TOP_BUILDDIR version: 1 updated: 2006/10/15 16:33:23
6155 dnl ---------------
6156 dnl Define a top_builddir symbol, for applications that need an absolute path.
6157 AC_DEFUN([CF_TOP_BUILDDIR],
6158 [
6159 top_builddir=`pwd`
6160 AC_SUBST(top_builddir)
6161 ])dnl
6162 dnl ---------------------------------------------------------------------------
6163 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
6164 dnl -------------------
6165 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
6166 dnl can define it successfully.
6167 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
6168 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
6169         AC_TRY_COMPILE([
6170 #include <stdlib.h>
6171 #include <string.h>
6172 #include <sys/types.h>
6173 ],[
6174 #ifndef _XOPEN_SOURCE
6175 make an error
6176 #endif],
6177         [cf_cv_xopen_source=no],
6178         [cf_save="$CPPFLAGS"
6179          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6180          AC_TRY_COMPILE([
6181 #include <stdlib.h>
6182 #include <string.h>
6183 #include <sys/types.h>
6184 ],[
6185 #ifdef _XOPEN_SOURCE
6186 make an error
6187 #endif],
6188         [cf_cv_xopen_source=no],
6189         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
6190         CPPFLAGS="$cf_save"
6191         ])
6192 ])
6193
6194 if test "$cf_cv_xopen_source" != no ; then
6195         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
6196         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
6197         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
6198         CF_ADD_CFLAGS($cf_temp_xopen_source)
6199 fi
6200 ])
6201 dnl ---------------------------------------------------------------------------
6202 dnl CF_TYPEOF_CHTYPE version: 8 updated: 2006/12/16 12:33:30
6203 dnl ----------------
6204 dnl Determine the type we should use for chtype (and attr_t, which is treated
6205 dnl as the same thing).  We want around 32 bits, so on most machines want a
6206 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
6207 dnl wide characters, we have to have a type compatible with that, as well.
6208 AC_DEFUN([CF_TYPEOF_CHTYPE],
6209 [
6210 AC_MSG_CHECKING([for type of chtype])
6211 AC_CACHE_VAL(cf_cv_typeof_chtype,[
6212                 AC_TRY_RUN([
6213 #define WANT_BITS 31
6214 #include <stdio.h>
6215 int main()
6216 {
6217         FILE *fp = fopen("cf_test.out", "w");
6218         if (fp != 0) {
6219                 char *result = "long";
6220                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
6221                         int n;
6222                         unsigned int x, y;
6223                         for (n = 0; n < WANT_BITS; n++) {
6224                                 x = (1 << n);
6225                                 y = (x >> n);
6226                                 if (y != 1 || x == 0) {
6227                                         x = 0;
6228                                         break;
6229                                 }
6230                         }
6231                         /*
6232                          * If x is nonzero, an int is big enough for the bits
6233                          * that we want.
6234                          */
6235                         result = (x != 0) ? "int" : "long";
6236                 }
6237                 fputs(result, fp);
6238                 fclose(fp);
6239         }
6240         ${cf_cv_main_return:-return}(0);
6241 }
6242                 ],
6243                 [cf_cv_typeof_chtype=`cat cf_test.out`],
6244                 [cf_cv_typeof_chtype=long],
6245                 [cf_cv_typeof_chtype=long])
6246                 rm -f cf_test.out
6247         ])
6248 AC_MSG_RESULT($cf_cv_typeof_chtype)
6249
6250 AC_SUBST(cf_cv_typeof_chtype)
6251 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype)
6252 ])dnl
6253 dnl ---------------------------------------------------------------------------
6254 dnl CF_TYPE_SIGACTION version: 3 updated: 2000/08/12 23:18:52
6255 dnl -----------------
6256 dnl
6257 AC_DEFUN([CF_TYPE_SIGACTION],
6258 [
6259 AC_MSG_CHECKING([for type sigaction_t])
6260 AC_CACHE_VAL(cf_cv_type_sigaction,[
6261         AC_TRY_COMPILE([
6262 #include <signal.h>],
6263                 [sigaction_t x],
6264                 [cf_cv_type_sigaction=yes],
6265                 [cf_cv_type_sigaction=no])])
6266 AC_MSG_RESULT($cf_cv_type_sigaction)
6267 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION)
6268 ])dnl
6269 dnl ---------------------------------------------------------------------------
6270 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
6271 dnl --------------------
6272 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
6273 dnl won't, but they're still there.
6274 AC_DEFUN([CF_UNSIGNED_LITERALS],
6275 [
6276 AC_MSG_CHECKING([if unsigned literals are legal])
6277 AC_CACHE_VAL(cf_cv_unsigned_literals,[
6278         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
6279                 [cf_cv_unsigned_literals=yes],
6280                 [cf_cv_unsigned_literals=no])
6281         ])
6282 AC_MSG_RESULT($cf_cv_unsigned_literals)
6283 ])dnl
6284 dnl ---------------------------------------------------------------------------
6285 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
6286 dnl --------
6287 dnl Make an uppercase version of a variable
6288 dnl $1=uppercase($2)
6289 AC_DEFUN([CF_UPPER],
6290 [
6291 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6292 ])dnl
6293 dnl ---------------------------------------------------------------------------
6294 dnl CF_UTF8_LIB version: 7 updated: 2010/06/20 09:24:28
6295 dnl -----------
6296 dnl Check for multibyte support, and if not found, utf8 compatibility library
6297 AC_DEFUN([CF_UTF8_LIB],
6298 [
6299 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
6300         cf_save_LIBS="$LIBS"
6301         AC_TRY_LINK([
6302 #include <stdlib.h>],[putwc(0,0);],
6303         [cf_cv_utf8_lib=yes],
6304         [CF_FIND_LINKAGE([
6305 #include <libutf8.h>],[putwc(0,0);],utf8,
6306                 [cf_cv_utf8_lib=add-on],
6307                 [cf_cv_utf8_lib=no])
6308 ])])
6309
6310 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
6311 # ncurses/ncursesw:
6312 if test "$cf_cv_utf8_lib" = "add-on" ; then
6313         AC_DEFINE(HAVE_LIBUTF8_H)
6314         CF_ADD_INCDIR($cf_cv_header_path_utf8)
6315         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
6316         CF_ADD_LIBS($cf_cv_library_file_utf8)
6317 fi
6318 ])dnl
6319 dnl ---------------------------------------------------------------------------
6320 dnl CF_VA_COPY version: 2 updated: 2010/03/04 05:37:29
6321 dnl ----------
6322 dnl check for va_copy, part of stdarg.h
6323 dnl Also, workaround for glibc's __va_copy, by checking for both.
6324 AC_DEFUN([CF_VA_COPY],[
6325 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
6326 AC_TRY_LINK([
6327 #include <stdarg.h>
6328 ],[
6329         static va_list dst;
6330         static va_list src;
6331         va_copy(dst, src)],
6332         cf_cv_have_va_copy=yes,
6333         cf_cv_have_va_copy=no)])
6334
6335 test "$cf_cv_have_va_copy" = yes && AC_DEFINE(HAVE_VA_COPY)
6336
6337 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
6338 AC_TRY_LINK([
6339 #include <stdarg.h>
6340 ],[
6341         static va_list dst;
6342         static va_list src;
6343         __va_copy(dst, src)],
6344         cf_cv_have___va_copy=yes,
6345         cf_cv_have___va_copy=no)])
6346
6347 test "$cf_cv_have___va_copy" = yes && AC_DEFINE(HAVE___VA_COPY)
6348 ])
6349 dnl ---------------------------------------------------------------------------
6350 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
6351 dnl ----------
6352 dnl Use AC_VERBOSE w/o the warnings
6353 AC_DEFUN([CF_VERBOSE],
6354 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
6355 CF_MSG_LOG([$1])
6356 ])dnl
6357 dnl ---------------------------------------------------------------------------
6358 dnl CF_WCHAR_TYPE version: 3 updated: 2010/05/26 16:44:57
6359 dnl -------------
6360 dnl Check if type wide-character type $1 is declared, and if so, which header
6361 dnl file is needed.  The second parameter is used to set a shell variable when
6362 dnl the type is not found.  The first parameter sets a shell variable for the
6363 dnl opposite sense.
6364 AC_DEFUN([CF_WCHAR_TYPE],
6365 [
6366 # This is needed on Tru64 5.0 to declare $1
6367 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
6368 AC_TRY_COMPILE([
6369 #include <stdlib.h>
6370 #include <stdarg.h>
6371 #include <stdio.h>
6372 #ifdef HAVE_LIBUTF8_H
6373 #include <libutf8.h>
6374 #endif],
6375         [$1 state],
6376         [cf_cv_$1=no],
6377         [AC_TRY_COMPILE([
6378 #include <stdlib.h>
6379 #include <stdarg.h>
6380 #include <stdio.h>
6381 #include <wchar.h>
6382 #ifdef HAVE_LIBUTF8_H
6383 #include <libutf8.h>
6384 #endif],
6385         [$1 value],
6386         [cf_cv_$1=yes],
6387         [cf_cv_$1=unknown])])])
6388
6389 if test "$cf_cv_$1" = yes ; then
6390         AC_DEFINE(NEED_WCHAR_H)
6391         NEED_WCHAR_H=1
6392 fi
6393
6394 ifelse([$2],,,[
6395 # if we do not find $1 in either place, use substitution to provide a fallback.
6396 if test "$cf_cv_$1" = unknown ; then
6397         $2=1
6398 fi
6399 ])
6400 ifelse($3,,,[
6401 # if we find $1 in either place, use substitution to provide a fallback.
6402 if test "$cf_cv_$1" != unknown ; then
6403         $3=1
6404 fi
6405 ])
6406 ])dnl
6407 dnl ---------------------------------------------------------------------------
6408 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
6409 dnl ---------------
6410 dnl Check for compiler-support for weak symbols.
6411 dnl This works with "recent" gcc.
6412 AC_DEFUN([CF_WEAK_SYMBOLS],[
6413 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
6414
6415 AC_TRY_COMPILE([
6416 #include <stdio.h>],
6417 [
6418 #if defined(__GNUC__)
6419 #  if defined __USE_ISOC99
6420 #    define _cat_pragma(exp)    _Pragma(#exp)
6421 #    define _weak_pragma(exp)   _cat_pragma(weak name)
6422 #  else
6423 #    define _weak_pragma(exp)
6424 #  endif
6425 #  define _declare(name)        __extension__ extern __typeof__(name) name
6426 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
6427 #endif
6428
6429 weak_symbol(fopen);
6430 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
6431 ])
6432 ])dnl
6433 dnl ---------------------------------------------------------------------------
6434 dnl CF_WITH_ABI_VERSION version: 1 updated: 2003/09/20 18:12:49
6435 dnl -------------------
6436 dnl Allow library's ABI to be overridden.  Generally this happens when a
6437 dnl packager has incremented the ABI past that used in the original package,
6438 dnl and wishes to keep doing this.
6439 dnl
6440 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
6441 dnl symbol.
6442 AC_DEFUN([CF_WITH_ABI_VERSION],[
6443 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
6444 AC_ARG_WITH(abi-version,
6445 [  --with-abi-version=XXX  override derived ABI version],
6446 [AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
6447  cf_cv_abi_version=$withval])
6448  CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
6449 ifelse($1,,,[
6450 $1_ABI=$cf_cv_abi_version
6451 ])
6452 ])dnl
6453 dnl ---------------------------------------------------------------------------
6454 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
6455 dnl --------------------
6456 dnl Command-line option to specify the Ada95 compiler.
6457 AC_DEFUN([CF_WITH_ADA_COMPILER],[
6458 AC_MSG_CHECKING(for ada-compiler)
6459 AC_ARG_WITH(ada-compiler,
6460         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
6461         [cf_ada_compiler=$withval],
6462         [cf_ada_compiler=gnatmake])
6463 AC_SUBST(cf_ada_compiler)
6464 AC_MSG_RESULT($cf_ada_compiler)
6465 ])dnl
6466 dnl ---------------------------------------------------------------------------
6467 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
6468 dnl -------------------
6469 dnl Command-line option to specify where Ada includes will install.
6470 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
6471 AC_MSG_CHECKING(for ada-include)
6472 CF_WITH_PATH(ada-include,
6473    [  --with-ada-include=DIR  Ada includes are in DIR],
6474    ADA_INCLUDE,
6475    PREFIX/share/ada/adainclude,
6476    [$]prefix/share/ada/adainclude)
6477 AC_SUBST(ADA_INCLUDE)
6478 AC_MSG_RESULT($ADA_INCLUDE)
6479 ])dnl
6480 dnl ---------------------------------------------------------------------------
6481 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
6482 dnl -------------------
6483 dnl Command-line option to specify where Ada objects will install.
6484 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
6485 AC_MSG_CHECKING(for ada-objects)
6486 CF_WITH_PATH(ada-objects,
6487    [  --with-ada-objects=DIR  Ada objects are in DIR],
6488    ADA_OBJECTS,
6489    PREFIX/lib/ada/adalib,
6490    [$]prefix/lib/ada/adalib)
6491 AC_SUBST(ADA_OBJECTS)
6492 AC_MSG_RESULT($ADA_OBJECTS)
6493 ])dnl
6494 dnl ---------------------------------------------------------------------------
6495 dnl CF_WITH_ADA_SHAREDLIB version: 2 updated: 2010/06/26 17:35:58
6496 dnl ---------------------
6497 dnl Command-line option to specify if an Ada95 shared-library should be built,
6498 dnl and optionally what its soname should be.
6499 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
6500 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
6501 AC_ARG_WITH(ada-sharedlib,
6502         [  --with-ada-sharedlib=XX build Ada95 shared-library],
6503         [with_ada_sharedlib=$withval],
6504         [with_ada_sharedlib=no])
6505 AC_MSG_RESULT($with_ada_sharedlib)
6506
6507 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
6508 MAKE_ADA_SHAREDLIB="#"
6509
6510 if test "x$with_ada_sharedlib" != xno
6511 then
6512         MAKE_ADA_SHAREDLIB=
6513         if test "x$with_ada_sharedlib" != xyes
6514         then
6515                 ADA_SHAREDLIB="$with_ada_sharedlib"
6516         fi
6517 fi
6518
6519 AC_SUBST(ADA_SHAREDLIB)
6520 AC_SUBST(MAKE_ADA_SHAREDLIB)
6521 ])dnl
6522 dnl ---------------------------------------------------------------------------
6523 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
6524 dnl ----------------
6525 dnl Configure-option for dbmalloc.  The optional parameter is used to override
6526 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6527 AC_DEFUN([CF_WITH_DBMALLOC],[
6528 CF_NO_LEAKS_OPTION(dbmalloc,
6529         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
6530         [USE_DBMALLOC])
6531
6532 if test "$with_dbmalloc" = yes ; then
6533         AC_CHECK_HEADER(dbmalloc.h,
6534                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
6535 fi
6536 ])dnl
6537 dnl ---------------------------------------------------------------------------
6538 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
6539 dnl ---------------
6540 dnl Configure-option for dmalloc.  The optional parameter is used to override
6541 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6542 AC_DEFUN([CF_WITH_DMALLOC],[
6543 CF_NO_LEAKS_OPTION(dmalloc,
6544         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
6545         [USE_DMALLOC])
6546
6547 if test "$with_dmalloc" = yes ; then
6548         AC_CHECK_HEADER(dmalloc.h,
6549                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
6550 fi
6551 ])dnl
6552 dnl ---------------------------------------------------------------------------
6553 dnl CF_WITH_GPM version: 7 updated: 2008/03/23 14:48:54
6554 dnl -----------
6555 dnl
6556 dnl The option parameter (if neither yes/no) is assumed to be the name of
6557 dnl the gpm library, e.g., for dynamic loading.
6558 AC_DEFUN([CF_WITH_GPM],
6559 [
6560 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
6561 AC_ARG_WITH(gpm,
6562         [  --with-gpm              use Alessandro Rubini's GPM library],
6563         [with_gpm=$withval],
6564         [with_gpm=maybe])
6565 AC_MSG_RESULT($with_gpm)
6566
6567 if test "$with_gpm" != no ; then
6568         AC_CHECK_HEADER(gpm.h,[
6569                 AC_DEFINE(HAVE_GPM_H)
6570                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
6571                         CF_VERBOSE(assuming we really have GPM library)
6572                         AC_DEFINE(HAVE_LIBGPM)
6573                 else
6574                         AC_CHECK_LIB(gpm,Gpm_Open,[:],[
6575                                 AC_MSG_ERROR(Cannot link with GPM library)
6576                 fi
6577                 with_gpm=yes
6578                 ])
6579         ],[
6580                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
6581                 with_gpm=no
6582         ])
6583 fi
6584 ])
6585 dnl ---------------------------------------------------------------------------
6586 dnl CF_WITH_LIBTOOL version: 28 updated: 2011/07/02 15:40:32
6587 dnl ---------------
6588 dnl Provide a configure option to incorporate libtool.  Define several useful
6589 dnl symbols for the makefile rules.
6590 dnl
6591 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
6592 dnl macros from libtool.m4 which is in the aclocal directory of automake.
6593 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
6594 dnl But that still does not work properly since the macro is expanded outside
6595 dnl the CF_WITH_LIBTOOL macro:
6596 dnl
6597 dnl     #!/bin/sh
6598 dnl     ACLOCAL=`aclocal --print-ac-dir`
6599 dnl     if test -z "$ACLOCAL" ; then
6600 dnl             echo cannot find aclocal directory
6601 dnl             exit 1
6602 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
6603 dnl             echo cannot find libtool.m4 file
6604 dnl             exit 1
6605 dnl     fi
6606 dnl
6607 dnl     LOCAL=aclocal.m4
6608 dnl     ORIG=aclocal.m4.orig
6609 dnl
6610 dnl     trap "mv $ORIG $LOCAL" 0 1 2 5 15
6611 dnl     rm -f $ORIG
6612 dnl     mv $LOCAL $ORIG
6613 dnl
6614 dnl     # sed the LIBTOOL= assignment to omit the current directory?
6615 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
6616 dnl     cat $ORIG >>$LOCAL
6617 dnl
6618 dnl     autoconf-257 $*
6619 dnl
6620 AC_DEFUN([CF_WITH_LIBTOOL],
6621 [
6622 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
6623 ifdef([AC_PROG_LIBTOOL],,[
6624 LIBTOOL=
6625 ])
6626 # common library maintenance symbols that are convenient for libtool scripts:
6627 LIB_CREATE='${AR} -cr'
6628 LIB_OBJECT='${OBJECTS}'
6629 LIB_SUFFIX=.a
6630 LIB_PREP="$RANLIB"
6631
6632 # symbols used to prop libtool up to enable it to determine what it should be
6633 # doing:
6634 LIB_CLEAN=
6635 LIB_COMPILE=
6636 LIB_LINK='${CC}'
6637 LIB_INSTALL=
6638 LIB_UNINSTALL=
6639
6640 AC_MSG_CHECKING(if you want to build libraries with libtool)
6641 AC_ARG_WITH(libtool,
6642         [  --with-libtool          generate libraries with libtool],
6643         [with_libtool=$withval],
6644         [with_libtool=no])
6645 AC_MSG_RESULT($with_libtool)
6646 if test "$with_libtool" != "no"; then
6647 ifdef([AC_PROG_LIBTOOL],[
6648         # missing_content_AC_PROG_LIBTOOL{{
6649         AC_PROG_LIBTOOL
6650         # missing_content_AC_PROG_LIBTOOL}}
6651 ],[
6652         if test "$with_libtool" != "yes" ; then
6653                 CF_PATH_SYNTAX(with_libtool)
6654                 LIBTOOL=$with_libtool
6655         else
6656                 AC_PATH_PROG(LIBTOOL,libtool)
6657         fi
6658         if test -z "$LIBTOOL" ; then
6659                 AC_MSG_ERROR(Cannot find libtool)
6660         fi
6661 ])dnl
6662         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${DESTDIR}${libdir} ${LIBTOOL_VERSION} `cut -f1 ${srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
6663         LIB_OBJECT='${OBJECTS:.o=.lo}'
6664         LIB_SUFFIX=.la
6665         LIB_CLEAN='${LIBTOOL} --mode=clean'
6666         LIB_COMPILE='${LIBTOOL} --mode=compile'
6667         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
6668         LIB_INSTALL='${LIBTOOL} --mode=install'
6669         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
6670         LIB_PREP=:
6671
6672         # Show the version of libtool
6673         AC_MSG_CHECKING(version of libtool)
6674
6675         # Save the version in a cache variable - this is not entirely a good
6676         # thing, but the version string from libtool is very ugly, and for
6677         # bug reports it might be useful to have the original string. "("
6678         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
6679         AC_MSG_RESULT($cf_cv_libtool_version)
6680         if test -z "$cf_cv_libtool_version" ; then
6681                 AC_MSG_ERROR(This is not GNU libtool)
6682         fi
6683
6684         # special hack to add -no-undefined (which libtool should do for itself)
6685         LT_UNDEF=
6686         case "$cf_cv_system_name" in #(vi
6687         cygwin*|mingw32*|uwin*|aix[[4-7]]) #(vi
6688                 LT_UNDEF=-no-undefined
6689                 ;;
6690         esac
6691         AC_SUBST([LT_UNDEF])
6692
6693         # special hack to add --tag option for C++ compiler
6694         case $cf_cv_libtool_version in #(vi
6695         1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*) #(vi
6696                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
6697                 LIBTOOL="$LIBTOOL --tag=CC"
6698                 ;;
6699         *)
6700                 LIBTOOL_CXX="$LIBTOOL"
6701                 ;;
6702         esac
6703 else
6704         LIBTOOL=""
6705         LIBTOOL_CXX=""
6706 fi
6707
6708 test -z "$LIBTOOL" && ECHO_LT=
6709
6710 AC_SUBST(LIBTOOL)
6711 AC_SUBST(LIBTOOL_CXX)
6712 AC_SUBST(LIBTOOL_OPTS)
6713
6714 AC_SUBST(LIB_CREATE)
6715 AC_SUBST(LIB_OBJECT)
6716 AC_SUBST(LIB_SUFFIX)
6717 AC_SUBST(LIB_PREP)
6718
6719 AC_SUBST(LIB_CLEAN)
6720 AC_SUBST(LIB_COMPILE)
6721 AC_SUBST(LIB_LINK)
6722 AC_SUBST(LIB_INSTALL)
6723 AC_SUBST(LIB_UNINSTALL)
6724
6725 ])dnl
6726 dnl ---------------------------------------------------------------------------
6727 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
6728 dnl ------------------
6729 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
6730 dnl "lib" prefix, e.g., because it used the dll naming convention.
6731 dnl
6732 dnl $1 = variable to set
6733 AC_DEFUN([CF_WITH_LIB_PREFIX],
6734 [
6735 AC_MSG_CHECKING(if you want to have a library-prefix)
6736 AC_ARG_WITH(lib-prefix,
6737         [  --with-lib-prefix       override library-prefix],
6738         [with_lib_prefix=$withval],
6739         [with_lib_prefix=auto])
6740 AC_MSG_RESULT($with_lib_prefix)
6741
6742 if test $with_lib_prefix = auto
6743 then
6744         CF_LIB_PREFIX($1)
6745 elif test $with_lib_prefix = no
6746 then
6747         LIB_PREFIX=
6748 else
6749         LIB_PREFIX=$with_lib_prefix
6750 fi
6751 ])dnl
6752 dnl ---------------------------------------------------------------------------
6753 dnl CF_WITH_PATH version: 10 updated: 2010/10/23 15:44:18
6754 dnl ------------
6755 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
6756 dnl defaulting to yes/no.
6757 dnl
6758 dnl $1 = option name
6759 dnl $2 = help-text
6760 dnl $3 = environment variable to set
6761 dnl $4 = default value, shown in the help-message, must be a constant
6762 dnl $5 = default value, if it's an expression & cannot be in the help-message
6763 dnl
6764 AC_DEFUN([CF_WITH_PATH],
6765 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
6766 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
6767 if ifelse([$5],,true,[test -n "$5"]) ; then
6768 CF_PATH_SYNTAX(withval)
6769 fi
6770 $3="$withval"
6771 AC_SUBST($3)dnl
6772 ])dnl
6773 dnl ---------------------------------------------------------------------------
6774 dnl CF_WITH_PATHLIST version: 7 updated: 2010/10/23 16:10:30
6775 dnl ----------------
6776 dnl Process an option specifying a list of colon-separated paths.
6777 dnl
6778 dnl $1 = option name
6779 dnl $2 = help-text
6780 dnl $3 = environment variable to set
6781 dnl $4 = default value, shown in the help-message, must be a constant
6782 dnl $5 = default value, if it's an expression & cannot be in the help-message
6783 dnl $6 = flag to tell if we want to define or substitute
6784 dnl
6785 AC_DEFUN([CF_WITH_PATHLIST],[
6786 AC_REQUIRE([CF_PATHSEP])
6787 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
6788 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
6789
6790 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
6791 cf_dst_path=
6792 for cf_src_path in $withval
6793 do
6794   CF_PATH_SYNTAX(cf_src_path)
6795   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}:"
6796   cf_dst_path="${cf_dst_path}${cf_src_path}"
6797 done
6798 IFS="$ac_save_ifs"
6799
6800 ifelse($6,define,[
6801 # Strip single quotes from the value, e.g., when it was supplied as a literal
6802 # for $4 or $5.
6803 case $cf_dst_path in #(vi
6804 \'*)
6805   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
6806   ;;
6807 esac
6808 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
6809 ])
6810
6811 eval '$3="$cf_dst_path"'
6812 AC_SUBST($3)dnl
6813
6814 ])dnl
6815 dnl ---------------------------------------------------------------------------
6816 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 2 updated: 2011/12/10 18:58:47
6817 dnl -------------------------
6818 dnl Allow the choice of the pkg-config library directory to be overridden.
6819 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
6820 if test "$PKG_CONFIG" != none ; then
6821         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
6822         AC_ARG_WITH(pkg-config-libdir,
6823                 [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
6824                 [PKG_CONFIG_LIBDIR=$withval],
6825                 [PKG_CONFIG_LIBDIR=yes])
6826
6827         case x$PKG_CONFIG_LIBDIR in #(vi
6828         x/*) #(vi
6829                 ;;
6830         xyes) #(vi
6831                 # look for the library directory using the same prefix as the executable
6832                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
6833                 case x`(arch) 2>/dev/null` in #(vi
6834                 *64) #(vi
6835                         for cf_config in $cf_path/share $cf_path/lib64 $cf_path/lib32 $cf_path/lib
6836                         do
6837                                 if test -d $cf_config/pkgconfig
6838                                 then
6839                                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
6840                                         break
6841                                 fi
6842                         done
6843                         ;;
6844                 *)
6845                         PKG_CONFIG_LIBDIR=$cf_path/lib/pkgconfig
6846                         ;;
6847                 esac
6848                 ;;
6849         *)
6850                 ;;
6851         esac
6852
6853         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
6854 fi
6855
6856 AC_SUBST(PKG_CONFIG_LIBDIR)
6857 ])dnl
6858 dnl ---------------------------------------------------------------------------
6859 dnl CF_WITH_PTHREAD version: 5 updated: 2011/12/10 19:01:56
6860 dnl ---------------
6861 dnl Check for POSIX thread library.
6862 AC_DEFUN([CF_WITH_PTHREAD],
6863 [
6864 AC_MSG_CHECKING(if you want to link with the pthread library)
6865 AC_ARG_WITH(pthread,
6866     [  --with-pthread          use POSIX thread library],
6867     [with_pthread=$withval],
6868     [with_pthread=no])
6869 AC_MSG_RESULT($with_pthread)
6870
6871 if test "$with_pthread" != no ; then
6872     AC_CHECK_HEADER(pthread.h,[
6873         AC_DEFINE(HAVE_PTHREADS_H)
6874
6875         for cf_lib_pthread in pthread c_r
6876         do
6877             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
6878             cf_save_LIBS="$LIBS"
6879             CF_ADD_LIB($cf_lib_pthread)
6880             AC_TRY_LINK([
6881 #include <pthread.h>
6882 ],[
6883                 int rc = pthread_create(0,0,0,0);
6884                 int r2 = pthread_mutexattr_settype(0, 0);
6885 ],[with_pthread=yes],[with_pthread=no])
6886             LIBS="$cf_save_LIBS"
6887             AC_MSG_RESULT($with_pthread)
6888             test "$with_pthread" = yes && break
6889         done
6890
6891         if test "$with_pthread" = yes ; then
6892             CF_ADD_LIB($cf_lib_pthread)
6893             AC_DEFINE(HAVE_LIBPTHREADS)
6894         else
6895             AC_MSG_ERROR(Cannot link with pthread library)
6896         fi
6897     ])
6898 fi
6899 ])
6900 dnl ---------------------------------------------------------------------------
6901 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
6902 dnl -------------------
6903 dnl Allow library's release-version to be overridden.  Generally this happens when a
6904 dnl packager has incremented the release-version past that used in the original package,
6905 dnl and wishes to keep doing this.
6906 dnl
6907 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
6908 dnl and {package}_MINOR symbols
6909 dnl symbol.
6910 AC_DEFUN([CF_WITH_REL_VERSION],[
6911 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
6912 AC_ARG_WITH(rel-version,
6913 [  --with-rel-version=XXX  override derived release version],
6914 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
6915  cf_cv_rel_version=$withval])
6916 ifelse($1,,[
6917  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
6918 ],[
6919  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
6920  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
6921  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
6922  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
6923 ])
6924 ])dnl
6925 dnl ---------------------------------------------------------------------------
6926 dnl CF_WITH_SYSMOUSE version: 2 updated: 2003/03/22 19:13:43
6927 dnl ----------------
6928 dnl If we can compile with sysmouse, make it available unless it is not wanted.
6929 AC_DEFUN([CF_WITH_SYSMOUSE],[
6930 # not everyone has "test -c"
6931 if test -c /dev/sysmouse 2>/dev/null ; then
6932 AC_MSG_CHECKING(if you want to use sysmouse)
6933 AC_ARG_WITH(sysmouse,
6934         [  --with-sysmouse         use sysmouse (FreeBSD console)],
6935         [cf_with_sysmouse=$withval],
6936         [cf_with_sysmouse=maybe])
6937         if test "$cf_with_sysmouse" != no ; then
6938         AC_TRY_COMPILE([
6939 #include <osreldate.h>
6940 #if (__FreeBSD_version >= 400017)
6941 #include <sys/consio.h>
6942 #include <sys/fbio.h>
6943 #else
6944 #include <machine/console.h>
6945 #endif
6946 ],[
6947         struct mouse_info the_mouse;
6948         ioctl(0, CONS_MOUSECTL, &the_mouse);
6949 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
6950         fi
6951 AC_MSG_RESULT($cf_with_sysmouse)
6952 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE)
6953 fi
6954 ])dnl
6955 dnl ---------------------------------------------------------------------------
6956 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
6957 dnl ----------------
6958 AC_DEFUN([CF_WITH_VALGRIND],[
6959 CF_NO_LEAKS_OPTION(valgrind,
6960         [  --with-valgrind         test: use valgrind],
6961         [USE_VALGRIND])
6962 ])dnl
6963 dnl ---------------------------------------------------------------------------
6964 dnl CF_XOPEN_SOURCE version: 42 updated: 2012/01/07 08:26:49
6965 dnl ---------------
6966 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
6967 dnl or adapt to the vendor's definitions to get equivalent functionality,
6968 dnl without losing the common non-POSIX features.
6969 dnl
6970 dnl Parameters:
6971 dnl     $1 is the nominal value for _XOPEN_SOURCE
6972 dnl     $2 is the nominal value for _POSIX_C_SOURCE
6973 AC_DEFUN([CF_XOPEN_SOURCE],[
6974
6975 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
6976 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
6977 cf_xopen_source=
6978
6979 case $host_os in #(vi
6980 aix[[4-7]]*) #(vi
6981         cf_xopen_source="-D_ALL_SOURCE"
6982         ;;
6983 cygwin) #(vi
6984         cf_XOPEN_SOURCE=600
6985         ;;
6986 darwin[[0-8]].*) #(vi
6987         cf_xopen_source="-D_APPLE_C_SOURCE"
6988         ;;
6989 darwin*) #(vi
6990         cf_xopen_source="-D_DARWIN_C_SOURCE"
6991         cf_XOPEN_SOURCE=
6992         ;;
6993 freebsd*|dragonfly*) #(vi
6994         # 5.x headers associate
6995         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
6996         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
6997         cf_POSIX_C_SOURCE=200112L
6998         cf_XOPEN_SOURCE=600
6999         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
7000         ;;
7001 hpux11*) #(vi
7002         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
7003         ;;
7004 hpux*) #(vi
7005         cf_xopen_source="-D_HPUX_SOURCE"
7006         ;;
7007 irix[[56]].*) #(vi
7008         cf_xopen_source="-D_SGI_SOURCE"
7009         cf_XOPEN_SOURCE=
7010         ;;
7011 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
7012         CF_GNU_SOURCE
7013         ;;
7014 mirbsd*) #(vi
7015         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
7016         cf_XOPEN_SOURCE=
7017         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7018         ;;
7019 netbsd*) #(vi
7020         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
7021         ;;
7022 openbsd[[4-9]]*) #(vi
7023         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
7024         cf_xopen_source="-D_BSD_SOURCE"
7025         cf_XOPEN_SOURCE=600
7026         ;;
7027 openbsd*) #(vi
7028         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
7029         ;;
7030 osf[[45]]*) #(vi
7031         cf_xopen_source="-D_OSF_SOURCE"
7032         ;;
7033 nto-qnx*) #(vi
7034         cf_xopen_source="-D_QNX_SOURCE"
7035         ;;
7036 sco*) #(vi
7037         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
7038         ;;
7039 solaris2.*) #(vi
7040         cf_xopen_source="-D__EXTENSIONS__"
7041         ;;
7042 *)
7043         CF_TRY_XOPEN_SOURCE
7044         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7045         ;;
7046 esac
7047
7048 if test -n "$cf_xopen_source" ; then
7049         CF_ADD_CFLAGS($cf_xopen_source)
7050 fi
7051
7052 dnl In anything but the default case, we may have system-specific setting
7053 dnl which is still not guaranteed to provide all of the entrypoints that
7054 dnl _XOPEN_SOURCE would yield.
7055 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
7056         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
7057         AC_TRY_COMPILE([#include <stdlib.h>],[
7058 #ifndef _XOPEN_SOURCE
7059 make an error
7060 #endif],
7061         [cf_XOPEN_SOURCE_set=yes],
7062         [cf_XOPEN_SOURCE_set=no])
7063         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
7064         if test $cf_XOPEN_SOURCE_set = yes
7065         then
7066                 AC_TRY_COMPILE([#include <stdlib.h>],[
7067 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
7068 make an error
7069 #endif],
7070                 [cf_XOPEN_SOURCE_set_ok=yes],
7071                 [cf_XOPEN_SOURCE_set_ok=no])
7072                 if test $cf_XOPEN_SOURCE_set_ok = no
7073                 then
7074                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
7075                 fi
7076         else
7077                 CF_TRY_XOPEN_SOURCE
7078         fi
7079 fi
7080 ])