aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2013,2014 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.720 2014/12/13 23:51:50 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 3 updated: 2002/10/27 23:21:42
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54     [AC_TRY_LINK([#include <langinfo.h>],
  55       [char* cs = nl_langinfo(CODESET);],
  56       am_cv_langinfo_codeset=yes,
  57       am_cv_langinfo_codeset=no)
  58     ])
  59   if test $am_cv_langinfo_codeset = yes; then
  60     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62   fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
  66 dnl ------------------
  67 dnl Conditionally generate script according to whether we're using a given autoconf.
  68 dnl
  69 dnl $1 = version to compare against
  70 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  71 dnl $3 = code to use if AC_ACVERSION is older than $1.
  72 define([CF_ACVERSION_CHECK],
  73 [
  74 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
  75 ifdef([m4_version_compare],
  76 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  77 [CF_ACVERSION_COMPARE(
  78 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  79 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  80 dnl ---------------------------------------------------------------------------
  81 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  82 dnl --------------------
  83 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  84 dnl                      MAJOR2, MINOR2, TERNARY2,
  85 dnl                      PRINTABLE2, not FOUND, FOUND)
  86 define([CF_ACVERSION_COMPARE],
  87 [ifelse(builtin([eval], [$2 < $5]), 1,
  88 [ifelse([$8], , ,[$8])],
  89 [ifelse([$9], , ,[$9])])])dnl
  90 dnl ---------------------------------------------------------------------------
  91 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
  92 dnl -------------------
  93 dnl Construct the list of include-options for the C programs in the Ada95
  94 dnl binding.
  95 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  96 [
  97 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  98 if test "$srcdir" != "."; then
  99         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 100 fi
 101 if test "$GCC" != yes; then
 102         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 103 elif test "$includedir" != "/usr/include"; then
 104         if test "$includedir" = '${prefix}/include' ; then
 105                 if test x$prefix != x/usr ; then
 106                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 107                 fi
 108         else
 109                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 110         fi
 111 fi
 112 AC_SUBST(ACPPFLAGS)
 113 ])dnl
 114 dnl ---------------------------------------------------------------------------
 115 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 116 dnl ---------------
 117 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 118 AC_DEFUN([CF_ADD_ADAFLAGS],[
 119         ADAFLAGS="$ADAFLAGS $1"
 120         AC_SUBST(ADAFLAGS)
 121 ])dnl
 122 dnl ---------------------------------------------------------------------------
 123 dnl CF_ADD_CFLAGS version: 11 updated: 2014/07/22 05:32:57
 124 dnl -------------
 125 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 126 dnl The second parameter if given makes this macro verbose.
 127 dnl
 128 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 129 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 130 dnl confused by the quotes (which require backslashes to keep them usable).
 131 AC_DEFUN([CF_ADD_CFLAGS],
 132 [
 133 cf_fix_cppflags=no
 134 cf_new_cflags=
 135 cf_new_cppflags=
 136 cf_new_extra_cppflags=
 137
 138 for cf_add_cflags in $1
 139 do
 140 case $cf_fix_cppflags in
 141 no)
 142         case $cf_add_cflags in #(vi
 143         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
 144                 case $cf_add_cflags in
 145                 -D*)
 146                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 147
 148                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 149                                 && test -z "${cf_tst_cflags}" \
 150                                 && cf_fix_cppflags=yes
 151
 152                         if test $cf_fix_cppflags = yes ; then
 153                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 154                                 continue
 155                         elif test "${cf_tst_cflags}" = "\"'" ; then
 156                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 157                                 continue
 158                         fi
 159                         ;;
 160                 esac
 161                 case "$CPPFLAGS" in
 162                 *$cf_add_cflags) #(vi
 163                         ;;
 164                 *) #(vi
 165                         case $cf_add_cflags in #(vi
 166                         -D*)
 167                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 168                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 169                                 ;;
 170                         esac
 171                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 172                         ;;
 173                 esac
 174                 ;;
 175         *)
 176                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 177                 ;;
 178         esac
 179         ;;
 180 yes)
 181         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 182
 183         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 184
 185         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 186                 && test -z "${cf_tst_cflags}" \
 187                 && cf_fix_cppflags=no
 188         ;;
 189 esac
 190 done
 191
 192 if test -n "$cf_new_cflags" ; then
 193         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 194         CFLAGS="$CFLAGS $cf_new_cflags"
 195 fi
 196
 197 if test -n "$cf_new_cppflags" ; then
 198         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 199         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 200 fi
 201
 202 if test -n "$cf_new_extra_cppflags" ; then
 203         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 204         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 205 fi
 206
 207 AC_SUBST(EXTRA_CPPFLAGS)
 208
 209 ])dnl
 210 dnl ---------------------------------------------------------------------------
 211 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 212 dnl -------------
 213 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 214 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 215 dnl but old versions (and some misinstalled ones) need that.  To make things
 216 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 217 dnl the include-path).
 218 AC_DEFUN([CF_ADD_INCDIR],
 219 [
 220 if test -n "$1" ; then
 221   for cf_add_incdir in $1
 222   do
 223         while test $cf_add_incdir != /usr/include
 224         do
 225           if test -d $cf_add_incdir
 226           then
 227                 cf_have_incdir=no
 228                 if test -n "$CFLAGS$CPPFLAGS" ; then
 229                   # a loop is needed to ensure we can add subdirs of existing dirs
 230                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 231                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 232                           cf_have_incdir=yes; break
 233                         fi
 234                   done
 235                 fi
 236
 237                 if test "$cf_have_incdir" = no ; then
 238                   if test "$cf_add_incdir" = /usr/local/include ; then
 239                         if test "$GCC" = yes
 240                         then
 241                           cf_save_CPPFLAGS=$CPPFLAGS
 242                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 243                           AC_TRY_COMPILE([#include <stdio.h>],
 244                                   [printf("Hello")],
 245                                   [],
 246                                   [cf_have_incdir=yes])
 247                           CPPFLAGS=$cf_save_CPPFLAGS
 248                         fi
 249                   fi
 250                 fi
 251
 252                 if test "$cf_have_incdir" = no ; then
 253                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 254                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 255
 256                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 257                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 258                   cf_add_incdir="$cf_top_incdir"
 259                 else
 260                   break
 261                 fi
 262           fi
 263         done
 264   done
 265 fi
 266 ])dnl
 267 dnl ---------------------------------------------------------------------------
 268 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 269 dnl ----------
 270 dnl Add a library, used to enforce consistency.
 271 dnl
 272 dnl $1 = library to add, without the "-l"
 273 dnl $2 = variable to update (default $LIBS)
 274 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 275 dnl ---------------------------------------------------------------------------
 276 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 277 dnl -------------
 278 dnl     Adds to the library-path
 279 dnl
 280 dnl     Some machines have trouble with multiple -L options.
 281 dnl
 282 dnl $1 is the (list of) directory(s) to add
 283 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 284 dnl
 285 AC_DEFUN([CF_ADD_LIBDIR],
 286 [
 287 if test -n "$1" ; then
 288   for cf_add_libdir in $1
 289   do
 290     if test $cf_add_libdir = /usr/lib ; then
 291       :
 292     elif test -d $cf_add_libdir
 293     then
 294       cf_have_libdir=no
 295       if test -n "$LDFLAGS$LIBS" ; then
 296         # a loop is needed to ensure we can add subdirs of existing dirs
 297         for cf_test_libdir in $LDFLAGS $LIBS ; do
 298           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 299             cf_have_libdir=yes; break
 300           fi
 301         done
 302       fi
 303       if test "$cf_have_libdir" = no ; then
 304         CF_VERBOSE(adding $cf_add_libdir to library-path)
 305         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 306       fi
 307     fi
 308   done
 309 fi
 310 ])dnl
 311 dnl ---------------------------------------------------------------------------
 312 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 313 dnl -----------
 314 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 315 dnl prepended to an existing list, since their dependencies are assumed to
 316 dnl already exist in the list.
 317 dnl
 318 dnl $1 = libraries to add, with the "-l", etc.
 319 dnl $2 = variable to update (default $LIBS)
 320 AC_DEFUN([CF_ADD_LIBS],[
 321 cf_add_libs="$1"
 322 # Filter out duplicates - this happens with badly-designed ".pc" files...
 323 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 324 do
 325         for cf_add_2lib in $cf_add_libs
 326         do
 327                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 328                 then
 329                         cf_add_1lib=
 330                         break
 331                 fi
 332         done
 333         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 334 done
 335 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 336 ])dnl
 337 dnl ---------------------------------------------------------------------------
 338 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 339 dnl ------------------
 340 dnl Append to a search-list for a nonstandard header/lib-file
 341 dnl     $1 = the variable to return as result
 342 dnl     $2 = the package name
 343 dnl     $3 = the subdirectory, e.g., bin, include or lib
 344 dnl $4 = the directory under which we will test for subdirectories
 345 dnl $5 = a directory that we do not want $4 to match
 346 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 347 [
 348 test "x$4" != "x$5" && \
 349 test -d "$4" && \
 350 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 351         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 352         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 353         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 354         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 355         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 356         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 357 }
 358 ])dnl
 359 dnl ---------------------------------------------------------------------------
 360 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 361 dnl --------------
 362 dnl Allow user to disable a normally-on option.
 363 AC_DEFUN([CF_ARG_DISABLE],
 364 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 365 dnl ---------------------------------------------------------------------------
 366 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 367 dnl -------------
 368 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 369 dnl values.
 370 dnl
 371 dnl Parameters:
 372 dnl $1 = option name
 373 dnl $2 = help-string
 374 dnl $3 = action to perform if option is not default
 375 dnl $4 = action if perform if option is default
 376 dnl $5 = default option value (either 'yes' or 'no')
 377 AC_DEFUN([CF_ARG_OPTION],
 378 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 379   if test "$enableval" != "$5" ; then
 380 ifelse([$3],,[    :]dnl
 381 ,[    $3]) ifelse([$4],,,[
 382   else
 383     $4])
 384   fi],[enableval=$5 ifelse([$4],,,[
 385   $4
 386 ])dnl
 387   ])])dnl
 388 dnl ---------------------------------------------------------------------------
 389 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 390 dnl -----------
 391 dnl Check for suitable "ar" (archiver) options for updating an archive.
 392 AC_DEFUN([CF_AR_FLAGS],[
 393 AC_REQUIRE([CF_PROG_AR])
 394
 395 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 396         cf_cv_ar_flags=unknown
 397         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 398         do
 399
 400                 # check if $ARFLAGS already contains this choice
 401                 if test "x$ARFLAGS" != "x" ; then
 402                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 403                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 404                                 cf_cv_ar_flags=
 405                                 break
 406                         fi
 407                 fi
 408
 409                 rm -f conftest.$ac_cv_objext
 410                 rm -f conftest.a
 411
 412                 cat >conftest.$ac_ext <<EOF
 413 #line __oline__ "configure"
 414 int     testdata[[3]] = { 123, 456, 789 };
 415 EOF
 416                 if AC_TRY_EVAL(ac_compile) ; then
 417                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 418                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 419                         if test -f conftest.a ; then
 420                                 cf_cv_ar_flags=$cf_ar_flags
 421                                 break
 422                         fi
 423                 else
 424                         CF_VERBOSE(cannot compile test-program)
 425                         break
 426                 fi
 427         done
 428         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 429 ])
 430
 431 if test -n "$ARFLAGS" ; then
 432         if test -n "$cf_cv_ar_flags" ; then
 433                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 434         fi
 435 else
 436         ARFLAGS=$cf_cv_ar_flags
 437 fi
 438
 439 AC_SUBST(ARFLAGS)
 440 ])
 441 dnl ---------------------------------------------------------------------------
 442 dnl CF_AWK_BIG_PRINTF version: 4 updated: 2011/10/30 17:09:50
 443 dnl -----------------
 444 dnl Check if awk can handle big strings using printf.  Some older versions of
 445 dnl awk choke on large strings passed via "%s".
 446 dnl
 447 dnl $1 = desired string size
 448 dnl $2 = variable to set with result
 449 AC_DEFUN([CF_AWK_BIG_PRINTF],
 450 [
 451         case x$AWK in #(vi
 452         x)
 453                 eval $2=no
 454                 ;;
 455         *) #(vi
 456                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 457                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 458                         eval $2=yes
 459                 else
 460                         eval $2=no
 461                 fi
 462                 ;;
 463         esac
 464 ])dnl
 465 dnl ---------------------------------------------------------------------------
 466 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 467 dnl ------------
 468 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 469 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 470 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 471 dnl
 472 dnl Treat the configuration-variable specially here, since we're directly
 473 dnl substituting its value (i.e., 1/0).
 474 dnl
 475 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 476 AC_DEFUN([CF_BOOL_DECL],
 477 [
 478 AC_MSG_CHECKING(if we should include stdbool.h)
 479
 480 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 481         AC_TRY_COMPILE([],[bool foo = false],
 482                 [cf_cv_header_stdbool_h=0],
 483                 [AC_TRY_COMPILE([
 484 #ifndef __BEOS__
 485 #include <stdbool.h>
 486 #endif
 487 ],[bool foo = false],
 488                         [cf_cv_header_stdbool_h=1],
 489                         [cf_cv_header_stdbool_h=0])])])
 490
 491 if test "$cf_cv_header_stdbool_h" = 1
 492 then    AC_MSG_RESULT(yes)
 493 else    AC_MSG_RESULT(no)
 494 fi
 495
 496 AC_MSG_CHECKING([for builtin bool type])
 497
 498 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 499         AC_TRY_COMPILE([
 500 #include <stdio.h>
 501 #include <sys/types.h>
 502 ],[bool x = false],
 503                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 504                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 505         ])
 506
 507 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 508 then    AC_MSG_RESULT(yes)
 509 else    AC_MSG_RESULT(no)
 510 fi
 511 ])dnl
 512 dnl ---------------------------------------------------------------------------
 513 dnl CF_BOOL_SIZE version: 13 updated: 2013/04/13 18:03:21
 514 dnl ------------
 515 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 516 dnl Don't bother looking for bool.h, since it's been deprecated.
 517 dnl
 518 dnl If the current compiler is C rather than C++, we get the bool definition
 519 dnl from <stdbool.h>.
 520 AC_DEFUN([CF_BOOL_SIZE],
 521 [
 522 AC_MSG_CHECKING([for size of bool])
 523 AC_CACHE_VAL(cf_cv_type_of_bool,[
 524         rm -f cf_test.out
 525         AC_TRY_RUN([
 526 #include <stdlib.h>
 527 #include <stdio.h>
 528
 529 #if defined(__cplusplus)
 530
 531 #ifdef HAVE_GXX_BUILTIN_H
 532 #include <g++/builtin.h>
 533 #elif HAVE_GPP_BUILTIN_H
 534 #include <gpp/builtin.h>
 535 #elif HAVE_BUILTIN_H
 536 #include <builtin.h>
 537 #endif
 538
 539 #else
 540
 541 #if $cf_cv_header_stdbool_h
 542 #include <stdbool.h>
 543 #endif
 544
 545 #endif
 546
 547 int main()
 548 {
 549         FILE *fp = fopen("cf_test.out", "w");
 550         if (fp != 0) {
 551                 bool x = true;
 552                 if ((bool)(-x) >= 0)
 553                         fputs("unsigned ", fp);
 554                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 555                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 556                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 557                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 558                 fclose(fp);
 559         }
 560         ${cf_cv_main_return:-return}(0);
 561 }
 562                 ],
 563                 [cf_cv_type_of_bool=`cat cf_test.out`
 564                  if test -z "$cf_cv_type_of_bool"; then
 565                    cf_cv_type_of_bool=unknown
 566                  fi],
 567                 [cf_cv_type_of_bool=unknown],
 568                 [cf_cv_type_of_bool=unknown])
 569         ])
 570         rm -f cf_test.out
 571 AC_MSG_RESULT($cf_cv_type_of_bool)
 572 if test "$cf_cv_type_of_bool" = unknown ; then
 573         case .$NCURSES_BOOL in #(vi
 574         .auto|.) NCURSES_BOOL=unsigned;;
 575         esac
 576         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 577         cf_cv_type_of_bool=$NCURSES_BOOL
 578 fi
 579 ])dnl
 580 dnl ---------------------------------------------------------------------------
 581 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 582 dnl -----------
 583 dnl If we're cross-compiling, allow the user to override the tools and their
 584 dnl options.  The configure script is oriented toward identifying the host
 585 dnl compiler, etc., but we need a build compiler to generate parts of the
 586 dnl source.
 587 dnl
 588 dnl $1 = default for $CPPFLAGS
 589 dnl $2 = default for $LIBS
 590 AC_DEFUN([CF_BUILD_CC],[
 591 CF_ACVERSION_CHECK(2.52,,
 592         [AC_REQUIRE([CF_PROG_EXT])])
 593 if test "$cross_compiling" = yes ; then
 594
 595         # defaults that we might want to override
 596         : ${BUILD_CFLAGS:=''}
 597         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 598         : ${BUILD_LDFLAGS:=''}
 599         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 600         : ${BUILD_EXEEXT:='$x'}
 601         : ${BUILD_OBJEXT:='o'}
 602
 603         AC_ARG_WITH(build-cc,
 604                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 605                 [BUILD_CC="$withval"],
 606                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 607         AC_MSG_CHECKING(for native build C compiler)
 608         AC_MSG_RESULT($BUILD_CC)
 609
 610         AC_MSG_CHECKING(for native build C preprocessor)
 611         AC_ARG_WITH(build-cpp,
 612                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 613                 [BUILD_CPP="$withval"],
 614                 [BUILD_CPP='${BUILD_CC} -E'])
 615         AC_MSG_RESULT($BUILD_CPP)
 616
 617         AC_MSG_CHECKING(for native build C flags)
 618         AC_ARG_WITH(build-cflags,
 619                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 620                 [BUILD_CFLAGS="$withval"])
 621         AC_MSG_RESULT($BUILD_CFLAGS)
 622
 623         AC_MSG_CHECKING(for native build C preprocessor-flags)
 624         AC_ARG_WITH(build-cppflags,
 625                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 626                 [BUILD_CPPFLAGS="$withval"])
 627         AC_MSG_RESULT($BUILD_CPPFLAGS)
 628
 629         AC_MSG_CHECKING(for native build linker-flags)
 630         AC_ARG_WITH(build-ldflags,
 631                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 632                 [BUILD_LDFLAGS="$withval"])
 633         AC_MSG_RESULT($BUILD_LDFLAGS)
 634
 635         AC_MSG_CHECKING(for native build linker-libraries)
 636         AC_ARG_WITH(build-libs,
 637                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 638                 [BUILD_LIBS="$withval"])
 639         AC_MSG_RESULT($BUILD_LIBS)
 640
 641         # this assumes we're on Unix.
 642         BUILD_EXEEXT=
 643         BUILD_OBJEXT=o
 644
 645         : ${BUILD_CC:='${CC}'}
 646
 647         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 648                 AC_MSG_ERROR([Cross-build requires two compilers.
 649 Use --with-build-cc to specify the native compiler.])
 650         fi
 651
 652 else
 653         : ${BUILD_CC:='${CC}'}
 654         : ${BUILD_CPP:='${CPP}'}
 655         : ${BUILD_CFLAGS:='${CFLAGS}'}
 656         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 657         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 658         : ${BUILD_LIBS:='${LIBS}'}
 659         : ${BUILD_EXEEXT:='$x'}
 660         : ${BUILD_OBJEXT:='o'}
 661 fi
 662
 663 AC_SUBST(BUILD_CC)
 664 AC_SUBST(BUILD_CPP)
 665 AC_SUBST(BUILD_CFLAGS)
 666 AC_SUBST(BUILD_CPPFLAGS)
 667 AC_SUBST(BUILD_LDFLAGS)
 668 AC_SUBST(BUILD_LIBS)
 669 AC_SUBST(BUILD_EXEEXT)
 670 AC_SUBST(BUILD_OBJEXT)
 671 ])dnl
 672 dnl ---------------------------------------------------------------------------
 673 dnl CF_CC_ENV_FLAGS version: 1 updated: 2012/10/03 05:25:49
 674 dnl ---------------
 675 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 676 dnl into CC.  This will not help with broken scripts that wrap the compiler with
 677 dnl options, but eliminates a more common category of user confusion.
 678 AC_DEFUN([CF_CC_ENV_FLAGS],
 679 [
 680 # This should have been defined by AC_PROG_CC
 681 : ${CC:=cc}
 682
 683 AC_MSG_CHECKING(\$CC variable)
 684 case "$CC" in #(vi
 685 *[[\ \  ]]-[[IUD]]*)
 686         AC_MSG_RESULT(broken)
 687         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 688         # humor him...
 689         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 690         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 691         CF_ADD_CFLAGS($cf_flags)
 692         ;;
 693 *)
 694         AC_MSG_RESULT(ok)
 695         ;;
 696 esac
 697 ])dnl
 698 dnl ---------------------------------------------------------------------------
 699 dnl CF_CFG_DEFAULTS version: 10 updated: 2013/09/07 13:54:05
 700 dnl ---------------
 701 dnl Determine the default configuration into which we'll install ncurses.  This
 702 dnl can be overridden by the user's command-line options.  There's two items to
 703 dnl look for:
 704 dnl     1. the prefix (e.g., /usr)
 705 dnl     2. the header files (e.g., /usr/include/ncurses)
 706 dnl We'll look for a previous installation of ncurses and use the same defaults.
 707 dnl
 708 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 709 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 710 dnl programs from a vendor's.
 711 AC_DEFUN([CF_CFG_DEFAULTS],
 712 [
 713 AC_MSG_CHECKING(for prefix)
 714 if test "x$prefix" = "xNONE" ; then
 715         case "$cf_cv_system_name" in
 716                 # non-vendor systems don't have a conflict
 717         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 718                 prefix=/usr
 719                 ;;
 720         *)      prefix=$ac_default_prefix
 721                 ;;
 722         esac
 723 fi
 724 AC_MSG_RESULT($prefix)
 725
 726 if test "x$prefix" = "xNONE" ; then
 727 AC_MSG_CHECKING(for default include-directory)
 728 test -n "$verbose" && echo 1>&AC_FD_MSG
 729 for cf_symbol in \
 730         $includedir \
 731         $includedir/ncurses \
 732         $prefix/include \
 733         $prefix/include/ncurses \
 734         /usr/local/include \
 735         /usr/local/include/ncurses \
 736         /usr/include \
 737         /usr/include/ncurses
 738 do
 739         cf_dir=`eval echo $cf_symbol`
 740         if test -f $cf_dir/curses.h ; then
 741         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 742                 includedir="$cf_symbol"
 743                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 744                 break
 745         fi
 746         fi
 747         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 748 done
 749 AC_MSG_RESULT($includedir)
 750 fi
 751 ])dnl
 752 dnl ---------------------------------------------------------------------------
 753 dnl CF_CGETENT version: 5 updated: 2012/10/06 17:56:13
 754 dnl ----------
 755 dnl Check if the terminal-capability database functions are available.  If not,
 756 dnl ncurses has a much-reduced version.
 757 AC_DEFUN([CF_CGETENT],[
 758 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 759 AC_TRY_LINK([
 760 #include <stdlib.h>],[
 761         char temp[128];
 762         char *buf = temp;
 763         char *db_array = temp;
 764         cgetent(&buf, &db_array, "vt100");
 765         cgetcap(buf, "tc", '=');
 766         cgetmatch(buf, "tc");
 767         ],
 768         [cf_cv_cgetent=yes],
 769         [cf_cv_cgetent=no])
 770 ])
 771
 772 if test "$cf_cv_cgetent" = yes
 773 then
 774         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 775 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 776 AC_TRY_LINK([
 777 #include <stdlib.h>],[
 778         char temp[128];
 779         char *buf = temp;
 780 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 781         const char *db_array = temp;
 782         cgetent(&buf, &db_array, "vt100");
 783 #endif
 784         cgetcap(buf, "tc", '=');
 785         cgetmatch(buf, "tc");
 786         ],
 787         [cf_cv_cgetent_const=yes],
 788         [cf_cv_cgetent_const=no])
 789 ])
 790         if test "$cf_cv_cgetent_const" = yes
 791         then
 792                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 793         fi
 794 fi
 795 ])dnl
 796 dnl ---------------------------------------------------------------------------
 797 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 798 dnl --------------
 799 dnl Check if we're accidentally using a cache from a different machine.
 800 dnl Derive the system name, as a check for reusing the autoconf cache.
 801 dnl
 802 dnl If we've packaged config.guess and config.sub, run that (since it does a
 803 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 804 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 805 dnl which is useful in cross-compiles.
 806 dnl
 807 dnl Note: we would use $ac_config_sub, but that is one of the places where
 808 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 809 AC_DEFUN([CF_CHECK_CACHE],
 810 [
 811 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 812         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 813         system_name="$host_os"
 814 else
 815         system_name="`(uname -s -r) 2>/dev/null`"
 816         if test -z "$system_name" ; then
 817                 system_name="`(hostname) 2>/dev/null`"
 818         fi
 819 fi
 820 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 821 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 822
 823 test -z "$system_name" && system_name="$cf_cv_system_name"
 824 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 825
 826 if test ".$system_name" != ".$cf_cv_system_name" ; then
 827         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 828         AC_MSG_ERROR("Please remove config.cache and try again.")
 829 fi
 830 ])dnl
 831 dnl ---------------------------------------------------------------------------
 832 dnl CF_CHECK_ERRNO version: 11 updated: 2010/05/26 05:38:42
 833 dnl --------------
 834 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 835 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 836 dnl ourselves.
 837 dnl
 838 dnl $1 = the name to check
 839 dnl $2 = the assumed type
 840 AC_DEFUN([CF_CHECK_ERRNO],
 841 [
 842 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 843     AC_TRY_COMPILE([
 844 #ifdef HAVE_STDLIB_H
 845 #include <stdlib.h>
 846 #endif
 847 #include <stdio.h>
 848 #include <sys/types.h>
 849 #include <errno.h> ],
 850     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 851     [cf_cv_dcl_$1=yes],
 852     [cf_cv_dcl_$1=no])
 853 ])
 854
 855 if test "$cf_cv_dcl_$1" = no ; then
 856     CF_UPPER(cf_result,decl_$1)
 857     AC_DEFINE_UNQUOTED($cf_result)
 858 fi
 859
 860 # It's possible (for near-UNIX clones) that the data doesn't exist
 861 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 862 ])dnl
 863 dnl ---------------------------------------------------------------------------
 864 dnl CF_CHECK_EXTERN_DATA version: 3 updated: 2001/12/30 18:03:23
 865 dnl --------------------
 866 dnl Check for existence of external data in the current set of libraries.  If
 867 dnl we can modify it, it's real enough.
 868 dnl $1 = the name to check
 869 dnl $2 = its type
 870 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 871 [
 872 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 873     AC_TRY_LINK([
 874 #undef $1
 875 extern $2 $1;
 876 ],
 877     [$1 = 2],
 878     [cf_cv_have_$1=yes],
 879     [cf_cv_have_$1=no])
 880 ])
 881
 882 if test "$cf_cv_have_$1" = yes ; then
 883     CF_UPPER(cf_result,have_$1)
 884     AC_DEFINE_UNQUOTED($cf_result)
 885 fi
 886
 887 ])dnl
 888 dnl ---------------------------------------------------------------------------
 889 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 890 dnl -------------------
 891 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 892 dnl is not "weak" - warn about this because it can create problems linking
 893 dnl applications with ncurses.
 894 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 895 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 896
 897 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 898 cf_cv_check_gpm_wgetch=unknown
 899 if test "$cross_compiling" != yes ; then
 900
 901 cat >conftest.$ac_ext <<CF_EOF
 902 #include <gpm.h>
 903 int main()
 904 {
 905         Gpm_Wgetch();
 906         ${cf_cv_main_return:-return}(0);
 907 }
 908 CF_EOF
 909
 910         cf_save_LIBS="$LIBS"
 911         # This only works if we can look at the symbol table.  If a shared
 912         # library is stripped for install, we cannot use that.  So we're forced
 913         # to rely on the static library, noting that some packagers may not
 914         # include it.
 915         LIBS="-static -lgpm -dynamic $LIBS"
 916         if AC_TRY_EVAL(ac_compile) ; then
 917                 if AC_TRY_EVAL(ac_link) ; then
 918                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 919                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 920                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 921                 fi
 922         fi
 923         rm -rf conftest*
 924         LIBS="$cf_save_LIBS"
 925 fi
 926 ])
 927
 928 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 929         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 930 fi
 931 ])])dnl
 932 dnl ---------------------------------------------------------------------------
 933 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
 934 dnl ------------------------
 935 dnl Show the version of libtool
 936 dnl
 937 dnl Save the version in a cache variable - this is not entirely a good thing,
 938 dnl but the version string from libtool is very ugly, and for bug reports it
 939 dnl might be useful to have the original string.
 940 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
 941 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
 942 then
 943         AC_MSG_CHECKING(version of $LIBTOOL)
 944         CF_LIBTOOL_VERSION
 945         AC_MSG_RESULT($cf_cv_libtool_version)
 946         if test -z "$cf_cv_libtool_version" ; then
 947                 AC_MSG_ERROR(This is not GNU libtool)
 948         fi
 949 else
 950         AC_MSG_ERROR(GNU libtool has not been found)
 951 fi
 952 ])dnl
 953 dnl ---------------------------------------------------------------------------
 954 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
 955 dnl ----------------
 956 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
 957 AC_DEFUN([CF_CHECK_WCHAR_H],[
 958 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
 959 AC_TRY_COMPILE(
 960 [
 961 #include <stdlib.h>
 962 #include <wchar.h>
 963 ],[
 964         wint_t foo = 0;
 965         int bar = iswpunct(foo)],
 966         [cf_cv_wchar_h_okay=yes],
 967         [cf_cv_wchar_h_okay=no])])
 968
 969 if test $cf_cv_wchar_h_okay = no
 970 then
 971         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 972 fi
 973 ])dnl
 974 dnl ---------------------------------------------------------------------------
 975 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
 976 dnl -----------------
 977 dnl Check if the given compiler is really clang.  clang's C driver defines
 978 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 979 dnl not ignore some gcc options.
 980 dnl
 981 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 982 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 983 dnl the wrappers for gcc and g++ warnings.
 984 dnl
 985 dnl $1 = GCC (default) or GXX
 986 dnl $2 = CLANG_COMPILER (default)
 987 dnl $3 = CFLAGS (default) or CXXFLAGS
 988 AC_DEFUN([CF_CLANG_COMPILER],[
 989 ifelse([$2],,CLANG_COMPILER,[$2])=no
 990
 991 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 992         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 993         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 994         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
 995         AC_TRY_COMPILE([],[
 996 #ifdef __clang__
 997 #else
 998 make an error
 999 #endif
1000 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1001 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1002 ],[])
1003         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1004         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1005 fi
1006 ])
1007 dnl ---------------------------------------------------------------------------
1008 dnl CF_CPP_PARAM_INIT version: 6 updated: 2012/10/06 17:56:13
1009 dnl -----------------
1010 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1011 dnl is a late feature for the standard and is not in some recent compilers
1012 dnl (1999/9/11).
1013 AC_DEFUN([CF_CPP_PARAM_INIT],
1014 [
1015 if test -n "$CXX"; then
1016 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1017         AC_LANG_SAVE
1018         AC_LANG_CPLUSPLUS
1019         AC_TRY_RUN([
1020 class TEST {
1021 private:
1022         int value;
1023 public:
1024         TEST(int x = 1);
1025         ~TEST();
1026 };
1027
1028 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1029 {
1030         value = x;
1031 }
1032 int main() { }
1033 ],
1034         [cf_cv_cpp_param_init=yes],
1035         [cf_cv_cpp_param_init=no],
1036         [cf_cv_cpp_param_init=unknown])
1037         AC_LANG_RESTORE
1038 ])
1039 fi
1040 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1041 ])dnl
1042 dnl ---------------------------------------------------------------------------
1043 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1044 dnl ------------------
1045 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1046 dnl not be supported in g++ before 3.0
1047 AC_DEFUN([CF_CPP_STATIC_CAST],
1048 [
1049 if test -n "$CXX"; then
1050
1051 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1052         AC_LANG_SAVE
1053         AC_LANG_CPLUSPLUS
1054
1055         AC_TRY_COMPILE([
1056 class NCursesPanel
1057 {
1058 public:
1059   NCursesPanel(int nlines,
1060                int ncols,
1061                int begin_y = 0,
1062                int begin_x = 0)
1063   {
1064   }
1065   NCursesPanel();
1066   ~NCursesPanel();
1067 };
1068
1069 template<class T> class NCursesUserPanel : public NCursesPanel
1070 {
1071 public:
1072   NCursesUserPanel (int nlines,
1073                     int ncols,
1074                     int begin_y = 0,
1075                     int begin_x = 0,
1076                     const T* p_UserData = static_cast<T*>(0))
1077     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1078   {
1079   };
1080   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1081   {
1082   };
1083
1084   virtual ~NCursesUserPanel() {};
1085 };
1086 ],[
1087         const char* p_UserData = static_cast<char*>(0)],
1088         [cf_cv_cpp_static_cast=yes],
1089         [cf_cv_cpp_static_cast=no])
1090
1091         AC_LANG_RESTORE
1092 ])
1093
1094 fi
1095
1096 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1097 ])dnl
1098 dnl ---------------------------------------------------------------------------
1099 dnl CF_CXX_AR_FLAGS version: 1 updated: 2011/10/29 08:35:34
1100 dnl ---------------
1101 dnl Setup special archiver flags for given compilers.
1102 AC_DEFUN([CF_CXX_AR_FLAGS],[
1103         CXX_AR='$(AR)'
1104         CXX_ARFLAGS='$(ARFLAGS)'
1105         case $cf_cv_system_name in #(vi
1106         irix*) #(vi
1107             if test "$GXX" != yes ; then
1108                 CXX_AR='$(CXX)'
1109                 CXX_ARFLAGS='-ar -o'
1110             fi
1111             ;;
1112         sco3.2v5*) #(vi
1113             CXXLDFLAGS="-u main"
1114             ;;
1115         solaris2*)
1116             if test "$GXX" != yes ; then
1117                 CXX_AR='$(CXX)'
1118                 CXX_ARFLAGS='-xar -o'
1119             fi
1120             ;;
1121         esac
1122         AC_SUBST(CXXLDFLAGS)
1123         AC_SUBST(CXX_AR)
1124         AC_SUBST(CXX_ARFLAGS)
1125 ])dnl
1126 dnl ---------------------------------------------------------------------------
1127 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1128 dnl -------------------------
1129 dnl For c++, check if iostream uses "std::" namespace.
1130 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1131 AC_CHECK_HEADERS(iostream)
1132 if test x"$ac_cv_header_iostream" = xyes ; then
1133         AC_MSG_CHECKING(if iostream uses std-namespace)
1134         AC_TRY_COMPILE([
1135 #include <iostream>
1136 using std::endl;
1137 using std::cerr;],[
1138 cerr << "testing" << endl;
1139 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1140         AC_MSG_RESULT($cf_iostream_namespace)
1141         if test "$cf_iostream_namespace" = yes ; then
1142                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1143         fi
1144 fi
1145 ])dnl
1146 dnl ---------------------------------------------------------------------------
1147 dnl CF_C_INLINE version: 4 updated: 2012/06/16 14:55:39
1148 dnl -----------
1149 dnl Check if the C compiler supports "inline".
1150 dnl $1 is the name of a shell variable to set if inline is supported
1151 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1152 AC_DEFUN([CF_C_INLINE],[
1153 AC_C_INLINE
1154 $1=
1155 if test "$ac_cv_c_inline" != no ; then
1156   $1=inline
1157   if test "$INTEL_COMPILER" = yes
1158   then
1159     :
1160   elif test "$CLANG_COMPILER" = yes
1161   then
1162     :
1163   elif test "$GCC" = yes
1164   then
1165     AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1166       cf_save_CFLAGS=$CFLAGS
1167       CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1168       AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1169       [${cf_cv_main_return:-return} foo()],
1170       [cf_cv_gcc_inline=yes],
1171       [cf_cv_gcc_inline=no])
1172       CFLAGS=$cf_save_CFLAGS
1173     ])
1174     if test "$cf_cv_gcc_inline" = yes ; then
1175         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1176     fi
1177   fi
1178 fi
1179 AC_SUBST($1)
1180 ])dnl
1181 dnl ---------------------------------------------------------------------------
1182 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1183 dnl ----------
1184 dnl "dirname" is not portable, so we fake it with a shell script.
1185 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1186 dnl ---------------------------------------------------------------------------
1187 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1188 dnl ---------------
1189 AC_DEFUN([CF_DIRS_TO_MAKE],
1190 [
1191 DIRS_TO_MAKE="lib"
1192 for cf_item in $cf_list_models
1193 do
1194         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1195         for cf_item2 in $DIRS_TO_MAKE
1196         do
1197                 test $cf_item2 = $cf_subdir && break
1198         done
1199         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1200 done
1201 for cf_dir in $DIRS_TO_MAKE
1202 do
1203         test ! -d $cf_dir && mkdir $cf_dir
1204 done
1205 AC_SUBST(DIRS_TO_MAKE)
1206 ])dnl
1207 dnl ---------------------------------------------------------------------------
1208 dnl CF_DISABLE_ECHO version: 12 updated: 2012/10/06 16:30:28
1209 dnl ---------------
1210 dnl You can always use "make -n" to see the actual options, but it's hard to
1211 dnl pick out/analyze warning messages when the compile-line is long.
1212 dnl
1213 dnl Sets:
1214 dnl     ECHO_LT - symbol to control if libtool is verbose
1215 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1216 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1217 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1218 dnl     ECHO_CC - symbol to put before any "cc" line
1219 dnl
1220 AC_DEFUN([CF_DISABLE_ECHO],[
1221 AC_MSG_CHECKING(if you want to see long compiling messages)
1222 CF_ARG_DISABLE(echo,
1223         [  --disable-echo          do not display "compiling" commands],
1224         [
1225     ECHO_LT='--silent'
1226     ECHO_LD='@echo linking [$]@;'
1227     RULE_CC='@echo compiling [$]<'
1228     SHOW_CC='@echo compiling [$]@'
1229     ECHO_CC='@'
1230 ],[
1231     ECHO_LT=''
1232     ECHO_LD=''
1233     RULE_CC=''
1234     SHOW_CC=''
1235     ECHO_CC=''
1236 ])
1237 AC_MSG_RESULT($enableval)
1238 AC_SUBST(ECHO_LT)
1239 AC_SUBST(ECHO_LD)
1240 AC_SUBST(RULE_CC)
1241 AC_SUBST(SHOW_CC)
1242 AC_SUBST(ECHO_CC)
1243 ])dnl
1244 dnl ---------------------------------------------------------------------------
1245 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1246 dnl ------------------------
1247 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1248 AC_MSG_CHECKING(if we want to use GNAT projects)
1249 CF_ARG_DISABLE(gnat-projects,
1250         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1251         [enable_gnat_projects=no],
1252         [enable_gnat_projects=yes])
1253 AC_MSG_RESULT($enable_gnat_projects)
1254 ])dnl
1255 dnl ---------------------------------------------------------------------------
1256 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1257 dnl ----------------
1258 dnl Combine no-leak checks with the libraries or tools that are used for the
1259 dnl checks.
1260 AC_DEFUN([CF_DISABLE_LEAKS],[
1261
1262 AC_REQUIRE([CF_WITH_DMALLOC])
1263 AC_REQUIRE([CF_WITH_DBMALLOC])
1264 AC_REQUIRE([CF_WITH_VALGRIND])
1265
1266 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1267 AC_ARG_ENABLE(leaks,
1268         [  --disable-leaks         test: free permanent memory, analyze leaks],
1269         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1270         : ${with_no_leaks:=no})
1271 AC_MSG_RESULT($with_no_leaks)
1272
1273 if test "$with_no_leaks" = yes ; then
1274         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1275         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1276 fi
1277 ])dnl
1278 dnl ---------------------------------------------------------------------------
1279 dnl CF_DISABLE_LIBTOOL_VERSION version: 2 updated: 2014/11/15 19:05:29
1280 dnl --------------------------
1281 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1282 dnl the older "-version-info" feature.  The newer feature allows us to use
1283 dnl version numbering on shared libraries which make them compatible with
1284 dnl various systems.
1285 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1286 [
1287 AC_MSG_CHECKING(if libtool -version-number should be used)
1288 CF_ARG_DISABLE(libtool-version,
1289         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1290         [cf_libtool_version=no],
1291         [cf_libtool_version=yes])
1292 AC_MSG_RESULT($cf_libtool_version)
1293
1294 if test "$cf_libtool_version" = yes ; then
1295         LIBTOOL_VERSION="-version-number"
1296 else
1297         LIBTOOL_VERSION="-version-info"
1298         case "x$VERSION" in #(vi
1299         x) #(vi
1300                 AC_MSG_WARN(VERSION was not set)
1301                 ;;
1302         x*.*.*)
1303                 ABI_VERSION="$VERSION"
1304                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1305                 ;;
1306         x*:*:*)
1307                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1308                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1309                 ;;
1310         *)
1311                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1312                 ;;
1313         esac
1314 fi
1315
1316 AC_SUBST(ABI_VERSION)
1317 AC_SUBST(LIBTOOL_VERSION)
1318 ])dnl
1319 dnl ---------------------------------------------------------------------------
1320 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1321 dnl ---------------------
1322 dnl The rpath-hack makes it simpler to build programs, particularly with the
1323 dnl *BSD ports which may have essential libraries in unusual places.  But it
1324 dnl can interfere with building an executable for the base system.  Use this
1325 dnl option in that case.
1326 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1327 [
1328 AC_MSG_CHECKING(if rpath-hack should be disabled)
1329 CF_ARG_DISABLE(rpath-hack,
1330         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1331         [cf_disable_rpath_hack=yes],
1332         [cf_disable_rpath_hack=no])
1333 AC_MSG_RESULT($cf_disable_rpath_hack)
1334 if test "$cf_disable_rpath_hack" = no ; then
1335         CF_RPATH_HACK
1336 fi
1337 ])
1338 dnl ---------------------------------------------------------------------------
1339 dnl CF_ENABLE_PC_FILES version: 10 updated: 2014/12/13 18:48:46
1340 dnl ------------------
1341 dnl This is the "--enable-pc-files" option, which is available if there is a
1342 dnl pkg-config configuration on the local machine.
1343 AC_DEFUN([CF_ENABLE_PC_FILES],[
1344 AC_REQUIRE([CF_PKG_CONFIG])
1345 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1346
1347 if test "x$PKG_CONFIG" != xnone
1348 then
1349         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1350 else
1351         AC_MSG_CHECKING(if we should install .pc files)
1352 fi
1353
1354 AC_ARG_ENABLE(pc-files,
1355         [  --enable-pc-files       generate and install .pc files for pkg-config],
1356         [enable_pc_files=$enableval],
1357         [enable_pc_files=no])
1358 AC_MSG_RESULT($enable_pc_files)
1359 if test "x$enable_pc_files" != xno
1360 then
1361         CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1362         MAKE_PC_FILES=
1363 else
1364         MAKE_PC_FILES="#"
1365 fi
1366 AC_SUBST(MAKE_PC_FILES)
1367 ])dnl
1368 dnl ---------------------------------------------------------------------------
1369 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1370 dnl ---------------
1371 dnl Check if the rpath option should be used, setting cache variable
1372 dnl cf_cv_enable_rpath if so.
1373 AC_DEFUN([CF_ENABLE_RPATH],
1374 [
1375 AC_MSG_CHECKING(if rpath option should be used)
1376 AC_ARG_ENABLE(rpath,
1377 [  --enable-rpath          use rpath option when generating shared libraries],
1378 [cf_cv_enable_rpath=$enableval],
1379 [cf_cv_enable_rpath=no])
1380 AC_MSG_RESULT($cf_cv_enable_rpath)
1381 ])dnl
1382 dnl ---------------------------------------------------------------------------
1383 dnl CF_ENABLE_STRING_HACKS version: 3 updated: 2013/01/26 16:26:12
1384 dnl ----------------------
1385 dnl On a few platforms, the compiler and/or loader nags with untruthful
1386 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1387 dnl and implying that most uses of the recommended alternatives are correct.
1388 dnl
1389 dnl Factually speaking, no one has actually counted the number of uses of these
1390 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1391 dnl instances are meaningless compared to the hundreds of millions of lines of
1392 dnl existing C code.
1393 dnl
1394 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1395 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1396 dnl standard - but evolved through phases, and older implementations are likely
1397 dnl to yield surprising results, as documented in manpages on various systems.
1398 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1399 [
1400 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1401 AC_ARG_ENABLE(string-hacks,
1402         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1403         [with_string_hacks=$enableval],
1404         [with_string_hacks=no])
1405 AC_MSG_RESULT($with_string_hacks)
1406
1407 if test "x$with_string_hacks" = "xyes"; then
1408         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1409         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1410         AC_CHECK_FUNCS( strlcat strlcpy snprintf )
1411 fi
1412 ])dnl
1413 dnl ---------------------------------------------------------------------------
1414 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1415 dnl --------
1416 dnl Check if 'errno' is declared in <errno.h>
1417 AC_DEFUN([CF_ERRNO],
1418 [
1419 CF_CHECK_ERRNO(errno)
1420 ])dnl
1421 dnl ---------------------------------------------------------------------------
1422 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1423 dnl ---------------
1424 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1425 dnl math.h and builtin.h, only for ncurses
1426 AC_DEFUN([CF_ETIP_DEFINES],
1427 [
1428 AC_MSG_CHECKING(for special defines needed for etip.h)
1429 cf_save_CXXFLAGS="$CXXFLAGS"
1430 cf_result="none"
1431
1432 # etip.h includes ncurses.h which includes ncurses_dll.h
1433 # But ncurses_dll.h is generated - fix here.
1434 test -d include || mkdir include
1435 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1436
1437 for cf_math in "" MATH_H
1438 do
1439 for cf_excp in "" MATH_EXCEPTION
1440 do
1441         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1442         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1443         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1444 AC_TRY_COMPILE([
1445 #include <etip.h.in>
1446 ],[],[
1447         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1448         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1449         cf_result="$cf_math $cf_excp"
1450         break 2
1451 ],[])
1452 done
1453 done
1454 AC_MSG_RESULT($cf_result)
1455 CXXFLAGS="$cf_save_CXXFLAGS"
1456 ])
1457 dnl ---------------------------------------------------------------------------
1458 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1459 dnl ---------------
1460 dnl Find a library (specifically the linkage used in the code fragment),
1461 dnl searching for it if it is not already in the library path.
1462 dnl See also CF_ADD_SEARCHPATH.
1463 dnl
1464 dnl Parameters (4-on are optional):
1465 dnl     $1 = headers for library entrypoint
1466 dnl     $2 = code fragment for library entrypoint
1467 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1468 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1469 dnl     $5 = action to perform if not successful
1470 dnl     $6 = module name, if not the same as the library name
1471 dnl     $7 = extra libraries
1472 dnl
1473 dnl Sets these variables:
1474 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1475 dnl     $cf_cv_header_path_$3 - include-directory if needed
1476 dnl     $cf_cv_library_path_$3 - library-directory if needed
1477 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1478 AC_DEFUN([CF_FIND_LINKAGE],[
1479
1480 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1481 # will be set on completion of the AC_TRY_LINK below.
1482 cf_cv_header_path_$3=
1483 cf_cv_library_path_$3=
1484
1485 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1486
1487 cf_save_LIBS="$LIBS"
1488
1489 AC_TRY_LINK([$1],[$2],[
1490         cf_cv_find_linkage_$3=yes
1491         cf_cv_header_path_$3=/usr/include
1492         cf_cv_library_path_$3=/usr/lib
1493 ],[
1494
1495 LIBS="-l$3 $7 $cf_save_LIBS"
1496
1497 AC_TRY_LINK([$1],[$2],[
1498         cf_cv_find_linkage_$3=yes
1499         cf_cv_header_path_$3=/usr/include
1500         cf_cv_library_path_$3=/usr/lib
1501         cf_cv_library_file_$3="-l$3"
1502 ],[
1503         cf_cv_find_linkage_$3=no
1504         LIBS="$cf_save_LIBS"
1505
1506     CF_VERBOSE(find linkage for $3 library)
1507     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1508
1509     cf_save_CPPFLAGS="$CPPFLAGS"
1510     cf_test_CPPFLAGS="$CPPFLAGS"
1511
1512     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1513     for cf_cv_header_path_$3 in $cf_search
1514     do
1515       if test -d $cf_cv_header_path_$3 ; then
1516         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1517         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1518         AC_TRY_COMPILE([$1],[$2],[
1519             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1520             cf_cv_find_linkage_$3=maybe
1521             cf_test_CPPFLAGS="$CPPFLAGS"
1522             break],[
1523             CPPFLAGS="$cf_save_CPPFLAGS"
1524             ])
1525       fi
1526     done
1527
1528     if test "$cf_cv_find_linkage_$3" = maybe ; then
1529
1530       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1531
1532       cf_save_LIBS="$LIBS"
1533       cf_save_LDFLAGS="$LDFLAGS"
1534
1535       ifelse([$6],,,[
1536         CPPFLAGS="$cf_test_CPPFLAGS"
1537         LIBS="-l$3 $7 $cf_save_LIBS"
1538         AC_TRY_LINK([$1],[$2],[
1539             CF_VERBOSE(... found $3 library in system)
1540             cf_cv_find_linkage_$3=yes])
1541             CPPFLAGS="$cf_save_CPPFLAGS"
1542             LIBS="$cf_save_LIBS"
1543             ])
1544
1545       if test "$cf_cv_find_linkage_$3" != yes ; then
1546         CF_LIBRARY_PATH(cf_search,$3)
1547         for cf_cv_library_path_$3 in $cf_search
1548         do
1549           if test -d $cf_cv_library_path_$3 ; then
1550             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1551             CPPFLAGS="$cf_test_CPPFLAGS"
1552             LIBS="-l$3 $7 $cf_save_LIBS"
1553             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1554             AC_TRY_LINK([$1],[$2],[
1555                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1556                 cf_cv_find_linkage_$3=yes
1557                 cf_cv_library_file_$3="-l$3"
1558                 break],[
1559                 CPPFLAGS="$cf_save_CPPFLAGS"
1560                 LIBS="$cf_save_LIBS"
1561                 LDFLAGS="$cf_save_LDFLAGS"
1562                 ])
1563           fi
1564         done
1565         CPPFLAGS="$cf_save_CPPFLAGS"
1566         LDFLAGS="$cf_save_LDFLAGS"
1567       fi
1568
1569     else
1570       cf_cv_find_linkage_$3=no
1571     fi
1572     ],$7)
1573 ])
1574
1575 LIBS="$cf_save_LIBS"
1576
1577 if test "$cf_cv_find_linkage_$3" = yes ; then
1578 ifelse([$4],,[
1579         CF_ADD_INCDIR($cf_cv_header_path_$3)
1580         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1581         CF_ADD_LIB($3)
1582 ],[$4])
1583 else
1584 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1585 fi
1586 ])dnl
1587 dnl ---------------------------------------------------------------------------
1588 dnl CF_FIND_SUB_INCDIR version: 1 updated: 2014/04/12 16:47:01
1589 dnl ------------------
1590 dnl Find an include-directory with the given leaf-name.  This is useful for
1591 dnl example with FreeBSD ports, which use this convention to distinguish
1592 dnl different versions of the same port.
1593 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1594         CF_SUBDIR_PATH(cf_search,$1,include)
1595         for cf_item in $cf_search
1596         do
1597                 case $cf_item in #(vi
1598                 */$1)
1599                         CF_ADD_INCDIR($cf_item)
1600                         ;;
1601                 esac
1602         done
1603 ])dnl
1604 dnl ---------------------------------------------------------------------------
1605 dnl CF_FIND_SUB_LIBDIR version: 1 updated: 2014/04/12 16:47:01
1606 dnl ------------------
1607 dnl Find a library-directory with the given leaf-name.  This is useful for
1608 dnl example with FreeBSD ports, which use this convention to distinguish
1609 dnl different versions of the same port.
1610 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1611         CF_SUBDIR_PATH(cf_search,$1,lib)
1612         for cf_item in $cf_search
1613         do
1614                 case $cf_item in #(vi
1615                 */$1)
1616                         CF_ADD_LIBDIR($cf_item)
1617                         ;;
1618                 esac
1619         done
1620 ])dnl
1621 dnl ---------------------------------------------------------------------------
1622 dnl CF_FIXUP_ADAFLAGS version: 1 updated: 2012/03/31 18:48:10
1623 dnl -----------------
1624 dnl make ADAFLAGS consistent with CFLAGS
1625 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1626         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1627         case "$CFLAGS" in
1628         *-g*)
1629                 CF_ADD_ADAFLAGS(-g)
1630                 ;;
1631         esac
1632         case "$CFLAGS" in
1633         *-O*)
1634                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1635                 CF_ADD_ADAFLAGS($cf_O_flag)
1636                 ;;
1637         esac
1638         AC_MSG_RESULT($ADAFLAGS)
1639 ])dnl
1640 dnl ---------------------------------------------------------------------------
1641 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1642 dnl --------------
1643 dnl Forget that we saw the given tool.
1644 AC_DEFUN([CF_FORGET_TOOL],[
1645 unset ac_cv_prog_ac_ct_$1
1646 unset ac_ct_$1
1647 unset $1
1648 ])dnl
1649 dnl ---------------------------------------------------------------------------
1650 dnl CF_FUNC_DLSYM version: 3 updated: 2012/10/06 11:17:15
1651 dnl -------------
1652 dnl Test for dlsym() and related functions, as well as libdl.
1653 dnl
1654 dnl Sets
1655 dnl     $cf_have_dlsym
1656 dnl     $cf_have_libdl
1657 AC_DEFUN([CF_FUNC_DLSYM],[
1658 cf_have_dlsym=no
1659 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1660
1661 cf_have_libdl=no
1662 AC_CHECK_LIB(dl,dlsym,[
1663         cf_have_dlsym=yes
1664         cf_have_libdl=yes])])
1665
1666 if test "$cf_have_dlsym" = yes ; then
1667         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1668
1669         AC_MSG_CHECKING(whether able to link to dl*() functions)
1670         AC_TRY_LINK([#include <dlfcn.h>],[
1671                 void *obj;
1672                 if ((obj = dlopen("filename", 0)) != 0) {
1673                         if (dlsym(obj, "symbolname") == 0) {
1674                         dlclose(obj);
1675                         }
1676                 }],[
1677                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1678                 AC_MSG_ERROR(Cannot link test program for libdl)])
1679         AC_MSG_RESULT(ok)
1680 else
1681         AC_MSG_ERROR(Cannot find dlsym function)
1682 fi
1683 ])
1684 dnl ---------------------------------------------------------------------------
1685 dnl CF_FUNC_MEMMOVE version: 8 updated: 2012/10/04 20:12:20
1686 dnl ---------------
1687 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1688 dnl is found, add our own version of memmove to the list of objects.
1689 AC_DEFUN([CF_FUNC_MEMMOVE],
1690 [
1691 AC_CHECK_FUNC(memmove,,[
1692 AC_CHECK_FUNC(bcopy,[
1693         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1694                 AC_TRY_RUN([
1695 int main() {
1696         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1697         char temp[40];
1698         bcopy(data, temp, sizeof(data));
1699         bcopy(temp+10, temp, 15);
1700         bcopy(temp+5, temp+15, 10);
1701         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1702 }
1703                 ],
1704                 [cf_cv_good_bcopy=yes],
1705                 [cf_cv_good_bcopy=no],
1706                 [cf_cv_good_bcopy=unknown])
1707                 ])
1708         ],[cf_cv_good_bcopy=no])
1709         if test "$cf_cv_good_bcopy" = yes ; then
1710                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1711         else
1712                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1713         fi
1714 ])])dnl
1715 dnl ---------------------------------------------------------------------------
1716 dnl CF_FUNC_NANOSLEEP version: 4 updated: 2012/10/06 17:56:13
1717 dnl -----------------
1718 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1719 dnl AIX 4.x, provide a non-working version.
1720 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1721 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1722 AC_TRY_RUN([
1723 #include <stdio.h>
1724 #include <errno.h>
1725 #include <time.h>
1726
1727 #ifdef HAVE_SYS_TIME_H
1728 #include <sys/time.h>
1729 #endif
1730
1731 int main() {
1732         struct timespec ts1, ts2;
1733         int code;
1734         ts1.tv_sec  = 0;
1735         ts1.tv_nsec = 750000000;
1736         ts2.tv_sec  = 0;
1737         ts2.tv_nsec = 0;
1738         errno = 0;
1739         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1740         ${cf_cv_main_return:-return}(code != 0);
1741 }
1742 ],
1743         [cf_cv_func_nanosleep=yes],
1744         [cf_cv_func_nanosleep=no],
1745         [cf_cv_func_nanosleep=unknown])])
1746
1747 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1748 ])
1749 dnl ---------------------------------------------------------------------------
1750 dnl CF_FUNC_OPENPTY version: 3 updated: 2010/05/29 16:31:02
1751 dnl ---------------
1752 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1753 dnl "util" library as well.
1754 AC_DEFUN([CF_FUNC_OPENPTY],
1755 [
1756 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1757 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1758     cf_save_LIBS="$LIBS"
1759     test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1760     for cf_header in pty.h libutil.h util.h
1761     do
1762     AC_TRY_LINK([
1763 #include <$cf_header>
1764 ],[
1765     int x = openpty((int *)0, (int *)0, (char *)0,
1766                    (struct termios *)0, (struct winsize *)0);
1767 ],[
1768         cf_cv_func_openpty=$cf_header
1769         break
1770 ],[
1771         cf_cv_func_openpty=no
1772 ])
1773     done
1774     LIBS="$cf_save_LIBS"
1775 ])
1776 ])dnl
1777 dnl ---------------------------------------------------------------------------
1778 dnl CF_FUNC_POLL version: 8 updated: 2012/10/04 05:24:07
1779 dnl ------------
1780 dnl See if the poll function really works.  Some platforms have poll(), but
1781 dnl it does not work for terminals or files.
1782 AC_DEFUN([CF_FUNC_POLL],[
1783 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1784 AC_TRY_RUN([
1785 #include <stdlib.h>
1786 #include <stdio.h>
1787 #include <unistd.h>
1788 #include <fcntl.h>
1789 #ifdef HAVE_POLL_H
1790 #include <poll.h>
1791 #else
1792 #include <sys/poll.h>
1793 #endif
1794 int main() {
1795         struct pollfd myfds;
1796         int ret;
1797
1798         /* check for Darwin bug with respect to "devices" */
1799         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
1800         if (myfds.fd < 0)
1801                 myfds.fd = 0;
1802         myfds.events = POLLIN;
1803         myfds.revents = 0;
1804
1805         ret = poll(&myfds, 1, 100);
1806
1807         if (ret < 0 || (myfds.revents & POLLNVAL)) {
1808                 ret = -1;
1809         } else {
1810                 int fd = 0;
1811                 if (!isatty(fd)) {
1812                         fd = open("/dev/tty", 2);       /* O_RDWR */
1813                 }
1814
1815                 if (fd >= 0) {
1816                         /* also check with standard input */
1817                         myfds.fd = fd;
1818                         myfds.events = POLLIN;
1819                         myfds.revents = 0;
1820                         ret = poll(&myfds, 1, 100);
1821                 } else {
1822                         ret = -1;
1823                 }
1824         }
1825         ${cf_cv_main_return:-return}(ret < 0);
1826 }],
1827         [cf_cv_working_poll=yes],
1828         [cf_cv_working_poll=no],
1829         [cf_cv_working_poll=unknown])])
1830 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
1831 ])dnl
1832 dnl ---------------------------------------------------------------------------
1833 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
1834 dnl ---------------
1835 dnl Some old/broken variations define tcgetattr() only as a macro in
1836 dnl termio(s).h
1837 AC_DEFUN([CF_FUNC_TERMIOS],[
1838 AC_REQUIRE([CF_STRUCT_TERMIOS])
1839 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1840 AC_TRY_LINK([
1841 #include <sys/types.h>
1842 #ifdef HAVE_UNISTD_H
1843 #include <unistd.h>
1844 #endif
1845 #ifdef HAVE_TERMIOS_H
1846 #include <termios.h>
1847 #define TTY struct termios
1848 #else
1849 #ifdef HAVE_TERMIO_H
1850 #include <termio.h>
1851 #define TTY struct termio
1852 #endif
1853 #endif
1854 ],[
1855 TTY foo;
1856 tcgetattr(1, &foo);],
1857 [cf_cv_have_tcgetattr=yes],
1858 [cf_cv_have_tcgetattr=no])])
1859 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
1860 ])dnl
1861 dnl ---------------------------------------------------------------------------
1862 dnl CF_FUNC_VSSCANF version: 4 updated: 2012/10/06 17:56:13
1863 dnl ---------------
1864 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1865 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1866 dnl other functions.
1867 AC_DEFUN([CF_FUNC_VSSCANF],
1868 [
1869 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1870 AC_TRY_LINK([
1871 #include <stdarg.h>
1872 #include <stdio.h>],[
1873         va_list ap;
1874         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1875 AC_TRY_LINK([
1876 #include <stdarg.h>
1877 #include <stdio.h>],[
1878     FILE strbuf;
1879     char *str = "from";
1880
1881     strbuf._flag = _IOREAD;
1882     strbuf._ptr = strbuf._base = (unsigned char *) str;
1883     strbuf._cnt = strlen(str);
1884     strbuf._file = _NFILE;
1885     return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1886 AC_TRY_LINK([
1887 #include <stdarg.h>
1888 #include <stdio.h>],[
1889     FILE strbuf;
1890     char *str = "from";
1891
1892     strbuf._flag = _IOREAD;
1893     strbuf._ptr = strbuf._base = (unsigned char *) str;
1894     strbuf._cnt = strlen(str);
1895     strbuf._file = _NFILE;
1896     return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1897 cf_cv_func_vsscanf=no])])])])
1898
1899 case $cf_cv_func_vsscanf in #(vi
1900 vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);; #(vi
1901 vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);; #(vi
1902 _doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
1903 esac
1904
1905 ])dnl
1906 dnl ---------------------------------------------------------------------------
1907 dnl CF_GCC_ATTRIBUTES version: 16 updated: 2012/10/02 20:55:03
1908 dnl -----------------
1909 dnl Test for availability of useful gcc __attribute__ directives to quiet
1910 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1911 dnl to documentation, unrecognized directives cause older compilers to barf.
1912 AC_DEFUN([CF_GCC_ATTRIBUTES],
1913 [
1914 if test "$GCC" = yes
1915 then
1916 cat > conftest.i <<EOF
1917 #ifndef GCC_PRINTF
1918 #define GCC_PRINTF 0
1919 #endif
1920 #ifndef GCC_SCANF
1921 #define GCC_SCANF 0
1922 #endif
1923 #ifndef GCC_NORETURN
1924 #define GCC_NORETURN /* nothing */
1925 #endif
1926 #ifndef GCC_UNUSED
1927 #define GCC_UNUSED /* nothing */
1928 #endif
1929 EOF
1930 if test "$GCC" = yes
1931 then
1932         AC_CHECKING([for $CC __attribute__ directives])
1933 cat > conftest.$ac_ext <<EOF
1934 #line __oline__ "${as_me:-configure}"
1935 #include "confdefs.h"
1936 #include "conftest.h"
1937 #include "conftest.i"
1938 #if     GCC_PRINTF
1939 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1940 #else
1941 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1942 #endif
1943 #if     GCC_SCANF
1944 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1945 #else
1946 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1947 #endif
1948 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1949 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1950 extern void foo(void) GCC_NORETURN;
1951 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1952 EOF
1953         cf_printf_attribute=no
1954         cf_scanf_attribute=no
1955         for cf_attribute in scanf printf unused noreturn
1956         do
1957                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1958                 cf_directive="__attribute__(($cf_attribute))"
1959                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1960
1961                 case $cf_attribute in #(vi
1962                 printf) #(vi
1963                         cf_printf_attribute=yes
1964                         cat >conftest.h <<EOF
1965 #define GCC_$cf_ATTRIBUTE 1
1966 EOF
1967                         ;;
1968                 scanf) #(vi
1969                         cf_scanf_attribute=yes
1970                         cat >conftest.h <<EOF
1971 #define GCC_$cf_ATTRIBUTE 1
1972 EOF
1973                         ;;
1974                 *) #(vi
1975                         cat >conftest.h <<EOF
1976 #define GCC_$cf_ATTRIBUTE $cf_directive
1977 EOF
1978                         ;;
1979                 esac
1980
1981                 if AC_TRY_EVAL(ac_compile); then
1982                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1983                         cat conftest.h >>confdefs.h
1984                         case $cf_attribute in #(vi
1985                         noreturn) #(vi
1986                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1987                                 ;;
1988                         printf) #(vi
1989                                 cf_value='/* nothing */'
1990                                 if test "$cf_printf_attribute" != no ; then
1991                                         cf_value='__attribute__((format(printf,fmt,var)))'
1992                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1993                                 fi
1994                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1995                                 ;;
1996                         scanf) #(vi
1997                                 cf_value='/* nothing */'
1998                                 if test "$cf_scanf_attribute" != no ; then
1999                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2000                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2001                                 fi
2002                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2003                                 ;;
2004                         unused) #(vi
2005                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2006                                 ;;
2007                         esac
2008                 fi
2009         done
2010 else
2011         fgrep define conftest.i >>confdefs.h
2012 fi
2013 rm -rf conftest*
2014 fi
2015 ])dnl
2016 dnl ---------------------------------------------------------------------------
2017 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
2018 dnl --------------
2019 dnl Find version of gcc
2020 AC_DEFUN([CF_GCC_VERSION],[
2021 AC_REQUIRE([AC_PROG_CC])
2022 GCC_VERSION=none
2023 if test "$GCC" = yes ; then
2024         AC_MSG_CHECKING(version of $CC)
2025         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2026         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2027         AC_MSG_RESULT($GCC_VERSION)
2028 fi
2029 ])dnl
2030 dnl ---------------------------------------------------------------------------
2031 dnl CF_GCC_WARNINGS version: 31 updated: 2013/11/19 19:23:35
2032 dnl ---------------
2033 dnl Check if the compiler supports useful warning options.  There's a few that
2034 dnl we don't use, simply because they're too noisy:
2035 dnl
2036 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2037 dnl     -Wredundant-decls (system headers make this too noisy)
2038 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2039 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2040 dnl             is enabled for ncurses using "--enable-const".
2041 dnl     -pedantic
2042 dnl
2043 dnl Parameter:
2044 dnl     $1 is an optional list of gcc warning flags that a particular
2045 dnl             application might want to use, e.g., "no-unused" for
2046 dnl             -Wno-unused
2047 dnl Special:
2048 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2049 dnl
2050 AC_DEFUN([CF_GCC_WARNINGS],
2051 [
2052 AC_REQUIRE([CF_GCC_VERSION])
2053 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2054 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2055
2056 cat > conftest.$ac_ext <<EOF
2057 #line __oline__ "${as_me:-configure}"
2058 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2059 EOF
2060
2061 if test "$INTEL_COMPILER" = yes
2062 then
2063 # The "-wdXXX" options suppress warnings:
2064 # remark #1419: external declaration in primary source file
2065 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2066 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2067 # remark #193: zero used for undefined preprocessing identifier
2068 # remark #593: variable "curs_sb_left_arrow" was set but never used
2069 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2070 # remark #869: parameter "tw" was never referenced
2071 # remark #981: operands are evaluated in unspecified order
2072 # warning #279: controlling expression is constant
2073
2074         AC_CHECKING([for $CC warning options])
2075         cf_save_CFLAGS="$CFLAGS"
2076         EXTRA_CFLAGS="-Wall"
2077         for cf_opt in \
2078                 wd1419 \
2079                 wd1683 \
2080                 wd1684 \
2081                 wd193 \
2082                 wd593 \
2083                 wd279 \
2084                 wd810 \
2085                 wd869 \
2086                 wd981
2087         do
2088                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2089                 if AC_TRY_EVAL(ac_compile); then
2090                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2091                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2092                 fi
2093         done
2094         CFLAGS="$cf_save_CFLAGS"
2095
2096 elif test "$GCC" = yes
2097 then
2098         AC_CHECKING([for $CC warning options])
2099         cf_save_CFLAGS="$CFLAGS"
2100         EXTRA_CFLAGS=
2101         cf_warn_CONST=""
2102         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2103         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2104         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2105         for cf_opt in W Wall \
2106                 Wbad-function-cast \
2107                 Wcast-align \
2108                 Wcast-qual \
2109                 Wdeclaration-after-statement \
2110                 Wextra \
2111                 Winline \
2112                 Wmissing-declarations \
2113                 Wmissing-prototypes \
2114                 Wnested-externs \
2115                 Wpointer-arith \
2116                 Wshadow \
2117                 Wstrict-prototypes \
2118                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2119         do
2120                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2121                 if AC_TRY_EVAL(ac_compile); then
2122                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2123                         case $cf_opt in #(vi
2124                         Wcast-qual) #(vi
2125                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2126                                 ;;
2127                         Winline) #(vi
2128                                 case $GCC_VERSION in
2129                                 [[34]].*)
2130                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2131                                         continue;;
2132                                 esac
2133                                 ;;
2134                         Wpointer-arith) #(vi
2135                                 case $GCC_VERSION in
2136                                 [[12]].*)
2137                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2138                                         continue;;
2139                                 esac
2140                                 ;;
2141                         esac
2142                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2143                 fi
2144         done
2145         CFLAGS="$cf_save_CFLAGS"
2146 fi
2147 rm -rf conftest*
2148
2149 AC_SUBST(EXTRA_CFLAGS)
2150 ])dnl
2151 dnl ---------------------------------------------------------------------------
2152 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2153 dnl ----------------
2154 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2155 dnl unistd.h or (nonstandard) in getopt.h
2156 AC_DEFUN([CF_GETOPT_HEADER],
2157 [
2158 AC_HAVE_HEADERS(unistd.h getopt.h)
2159 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2160 cf_cv_getopt_header=none
2161 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2162 do
2163 AC_TRY_COMPILE([
2164 #include <$cf_header>],
2165 [int x = optind; char *y = optarg],
2166 [cf_cv_getopt_header=$cf_header
2167  break])
2168 done
2169 ])
2170 if test $cf_cv_getopt_header != none ; then
2171         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2172 fi
2173 if test $cf_cv_getopt_header = getopt.h ; then
2174         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2175 fi
2176 ])dnl
2177 dnl ---------------------------------------------------------------------------
2178 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2179 dnl -----------------
2180 AC_DEFUN([CF_GNATPREP_OPT_T],[
2181 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2182 cf_cv_gnatprep_opt_t=no
2183 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2184 ])
2185 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2186 AC_SUBST(GNATPREP_OPTS)
2187 ])dnl
2188 dnl ---------------------------------------------------------------------------
2189 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
2190 dnl ----------------
2191 AC_DEFUN([CF_GNAT_GENERICS],
2192 [
2193 AC_REQUIRE([CF_GNAT_VERSION])
2194
2195 AC_MSG_CHECKING(if GNAT supports generics)
2196 case $cf_gnat_version in #(vi
2197 3.[[1-9]]*|[[4-9]].*) #(vi
2198         cf_gnat_generics=yes
2199         ;;
2200 *)
2201         cf_gnat_generics=no
2202         ;;
2203 esac
2204 AC_MSG_RESULT($cf_gnat_generics)
2205
2206 if test "$cf_gnat_generics" = yes
2207 then
2208         cf_compile_generics=generics
2209         cf_generic_objects="\${GENOBJS}"
2210 else
2211         cf_compile_generics=
2212         cf_generic_objects=
2213 fi
2214
2215 AC_SUBST(cf_compile_generics)
2216 AC_SUBST(cf_generic_objects)
2217 ])dnl
2218 dnl ---------------------------------------------------------------------------
2219 dnl CF_GNAT_PROJECTS version: 7 updated: 2014/06/01 10:46:34
2220 dnl ----------------
2221 dnl GNAT projects are configured with ".gpr" project files.
2222 dnl GNAT libraries are a further development, using the project feature.
2223 AC_DEFUN([CF_GNAT_PROJECTS],
2224 [
2225 AC_REQUIRE([CF_GNAT_VERSION])
2226 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2227
2228 cf_gnat_libraries=no
2229 cf_gnat_projects=no
2230
2231 if test "$enable_gnat_projects" != no ; then
2232 AC_MSG_CHECKING(if GNAT supports project files)
2233 case $cf_gnat_version in #(vi
2234 3.[[0-9]]*) #(vi
2235         ;;
2236 *)
2237         case $cf_cv_system_name in #(vi
2238         cygwin*|msys*) #(vi
2239                 ;;
2240         *)
2241                 mkdir conftest.src conftest.bin conftest.lib
2242                 cd conftest.src
2243                 rm -rf conftest* *~conftest*
2244                 cat >>library.gpr <<CF_EOF
2245 project Library is
2246   Kind := External ("LIB_KIND");
2247   for Library_Name use "ConfTest";
2248   for Object_Dir use ".";
2249   for Library_ALI_Dir use External("LIBRARY_DIR");
2250   for Library_Version use External ("SONAME");
2251   for Library_Kind use Kind;
2252   for Library_Dir use External("BUILD_DIR");
2253   Source_Dir := External ("SOURCE_DIR");
2254   for Source_Dirs use (Source_Dir);
2255 end Library;
2256 CF_EOF
2257                 cat >>confpackage.ads <<CF_EOF
2258 package ConfPackage is
2259    procedure conftest;
2260 end ConfPackage;
2261 CF_EOF
2262                 cat >>confpackage.adb <<CF_EOF
2263 with Text_IO;
2264 package body ConfPackage is
2265    procedure conftest is
2266    begin
2267       Text_IO.Put ("Hello World");
2268       Text_IO.New_Line;
2269    end conftest;
2270 end ConfPackage;
2271 CF_EOF
2272                 if ( $cf_ada_make $ADAFLAGS \
2273                                 -Plibrary.gpr \
2274                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2275                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2276                                 -XSOURCE_DIR=`pwd` \
2277                                 -XSONAME=libConfTest.so.1 \
2278                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2279                         cf_gnat_projects=yes
2280                 fi
2281                 cd ..
2282                 if test -f conftest.lib/confpackage.ali
2283                 then
2284                         cf_gnat_libraries=yes
2285                 fi
2286                 rm -rf conftest* *~conftest*
2287                 ;;
2288         esac
2289         ;;
2290 esac
2291 AC_MSG_RESULT($cf_gnat_projects)
2292 fi # enable_gnat_projects
2293
2294 if test $cf_gnat_projects = yes
2295 then
2296         AC_MSG_CHECKING(if GNAT supports libraries)
2297         AC_MSG_RESULT($cf_gnat_libraries)
2298 fi
2299
2300 if test "$cf_gnat_projects" = yes
2301 then
2302         USE_OLD_MAKERULES="#"
2303         USE_GNAT_PROJECTS=""
2304 else
2305         USE_OLD_MAKERULES=""
2306         USE_GNAT_PROJECTS="#"
2307 fi
2308
2309 if test "$cf_gnat_libraries" = yes
2310 then
2311         USE_GNAT_LIBRARIES=""
2312 else
2313         USE_GNAT_LIBRARIES="#"
2314 fi
2315
2316 AC_SUBST(USE_OLD_MAKERULES)
2317 AC_SUBST(USE_GNAT_PROJECTS)
2318 AC_SUBST(USE_GNAT_LIBRARIES)
2319 ])dnl
2320 dnl ---------------------------------------------------------------------------
2321 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2322 dnl --------------
2323 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2324 dnl is noted that gnat may compile a tasking unit even for configurations which
2325 dnl fail at runtime.
2326 AC_DEFUN([CF_GNAT_SIGINT],[
2327 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2328 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2329
2330 package ConfTest is
2331
2332    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2333    pragma Unreserve_All_Interrupts;
2334    pragma Warnings (On);
2335
2336    protected Process is
2337       procedure Stop;
2338       function Continue return Boolean;
2339       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2340    private
2341       Done : Boolean := False;
2342    end Process;
2343
2344 end ConfTest;],
2345 [package body ConfTest is
2346    protected body Process is
2347       procedure Stop is
2348       begin
2349          Done := True;
2350       end Stop;
2351       function Continue return Boolean is
2352       begin
2353          return not Done;
2354       end Continue;
2355    end Process;
2356 end ConfTest;],
2357         [cf_cv_gnat_sigint=yes],
2358         [cf_cv_gnat_sigint=no])])
2359
2360 if test $cf_cv_gnat_sigint = yes ; then
2361         USE_GNAT_SIGINT=""
2362 else
2363         USE_GNAT_SIGINT="#"
2364 fi
2365 AC_SUBST(USE_GNAT_SIGINT)
2366 ])dnl
2367 dnl ---------------------------------------------------------------------------
2368 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2369 dnl ----------------
2370 dnl Verify that a test program compiles/links with GNAT.
2371 dnl $cf_ada_make is set to the program that compiles/links
2372 dnl $ADAFLAGS may be set to the GNAT flags.
2373 dnl
2374 dnl $1 is the text of the spec
2375 dnl $2 is the text of the body
2376 dnl $3 is the shell command to execute if successful
2377 dnl $4 is the shell command to execute if not successful
2378 AC_DEFUN([CF_GNAT_TRY_LINK],
2379 [
2380 rm -rf conftest* *~conftest*
2381 cat >>conftest.ads <<CF_EOF
2382 $1
2383 CF_EOF
2384 cat >>conftest.adb <<CF_EOF
2385 $2
2386 CF_EOF
2387 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2388 ifelse($3,,      :,[      $3])
2389 ifelse($4,,,[else
2390    $4])
2391 fi
2392 rm -rf conftest* *~conftest*
2393 ])dnl
2394 dnl ---------------------------------------------------------------------------
2395 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2396 dnl ---------------
2397 dnl Verify that a test program compiles and runs with GNAT
2398 dnl $cf_ada_make is set to the program that compiles/links
2399 dnl $ADAFLAGS may be set to the GNAT flags.
2400 dnl
2401 dnl $1 is the text of the spec
2402 dnl $2 is the text of the body
2403 dnl $3 is the shell command to execute if successful
2404 dnl $4 is the shell command to execute if not successful
2405 AC_DEFUN([CF_GNAT_TRY_RUN],
2406 [
2407 rm -rf conftest* *~conftest*
2408 cat >>conftest.ads <<CF_EOF
2409 $1
2410 CF_EOF
2411 cat >>conftest.adb <<CF_EOF
2412 $2
2413 CF_EOF
2414 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2415    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2416 ifelse($3,,      :,[      $3])
2417 ifelse($4,,,[   else
2418       $4])
2419    fi
2420 ifelse($4,,,[else
2421    $4])
2422 fi
2423 rm -rf conftest* *~conftest*
2424 ])dnl
2425 dnl ---------------------------------------------------------------------------
2426 dnl CF_GNAT_VERSION version: 18 updated: 2012/01/21 19:28:10
2427 dnl ---------------
2428 dnl Verify version of GNAT.
2429 AC_DEFUN([CF_GNAT_VERSION],
2430 [
2431 AC_MSG_CHECKING(for gnat version)
2432 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2433         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2434     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2435 AC_MSG_RESULT($cf_gnat_version)
2436
2437 case $cf_gnat_version in #(vi
2438 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]]) #(vi
2439         cf_cv_prog_gnat_correct=yes
2440         ;;
2441 *)
2442         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2443         cf_cv_prog_gnat_correct=no
2444         ;;
2445 esac
2446 ])
2447 dnl ---------------------------------------------------------------------------
2448 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2449 dnl -------------
2450 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2451 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2452 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2453 dnl since it is interwoven with GNU extensions.
2454 dnl
2455 dnl Well, yes we could work around it...
2456 AC_DEFUN([CF_GNU_SOURCE],
2457 [
2458 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2459 AC_TRY_COMPILE([#include <sys/types.h>],[
2460 #ifndef _XOPEN_SOURCE
2461 make an error
2462 #endif],
2463         [cf_cv_gnu_source=no],
2464         [cf_save="$CPPFLAGS"
2465          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2466          AC_TRY_COMPILE([#include <sys/types.h>],[
2467 #ifdef _XOPEN_SOURCE
2468 make an error
2469 #endif],
2470         [cf_cv_gnu_source=no],
2471         [cf_cv_gnu_source=yes])
2472         CPPFLAGS="$cf_save"
2473         ])
2474 ])
2475 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2476 ])dnl
2477 dnl ---------------------------------------------------------------------------
2478 dnl CF_GPP_LIBRARY version: 11 updated: 2012/10/06 17:56:13
2479 dnl --------------
2480 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2481 dnl problem :-).  If we have the compiler but no library, we'll be able to
2482 dnl configure, but won't be able to build the c++ demo program.
2483 AC_DEFUN([CF_GPP_LIBRARY],
2484 [
2485 cf_cxx_library=unknown
2486 case $cf_cv_system_name in #(vi
2487 os2*) #(vi
2488         cf_gpp_libname=gpp
2489         ;;
2490 *)
2491         cf_gpp_libname=g++
2492         ;;
2493 esac
2494 if test "$GXX" = yes; then
2495         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2496         cf_save="$LIBS"
2497         CF_ADD_LIB($cf_gpp_libname)
2498         AC_TRY_LINK([
2499 #include <$cf_gpp_libname/builtin.h>
2500         ],
2501         [two_arg_error_handler_t foo2 = lib_error_handler],
2502         [cf_cxx_library=yes
2503          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2504          if test "$cf_gpp_libname" = cpp ; then
2505             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2506          else
2507             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2508          fi],
2509         [AC_TRY_LINK([
2510 #include <builtin.h>
2511         ],
2512         [two_arg_error_handler_t foo2 = lib_error_handler],
2513         [cf_cxx_library=yes
2514          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2515          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2516         [cf_cxx_library=no])])
2517         LIBS="$cf_save"
2518         AC_MSG_RESULT($cf_cxx_library)
2519 fi
2520 ])dnl
2521 dnl ---------------------------------------------------------------------------
2522 dnl CF_GXX_VERSION version: 7 updated: 2012/06/16 14:55:39
2523 dnl --------------
2524 dnl Check for version of g++
2525 AC_DEFUN([CF_GXX_VERSION],[
2526 AC_REQUIRE([AC_PROG_CPP])
2527 GXX_VERSION=none
2528 if test "$GXX" = yes; then
2529         AC_MSG_CHECKING(version of ${CXX:-g++})
2530         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2531         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2532         AC_MSG_RESULT($GXX_VERSION)
2533 fi
2534 ])dnl
2535 dnl ---------------------------------------------------------------------------
2536 dnl CF_GXX_WARNINGS version: 8 updated: 2013/11/16 14:27:53
2537 dnl ---------------
2538 dnl Check if the compiler supports useful warning options.
2539 dnl
2540 dnl Most of gcc's options apply to g++, except:
2541 dnl     -Wbad-function-cast
2542 dnl     -Wmissing-declarations
2543 dnl     -Wnested-externs
2544 dnl
2545 dnl Omit a few (for now):
2546 dnl     -Winline
2547 dnl
2548 dnl Parameter:
2549 dnl     $1 is an optional list of g++ warning flags that a particular
2550 dnl             application might want to use, e.g., "no-unused" for
2551 dnl             -Wno-unused
2552 dnl Special:
2553 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2554 dnl
2555 AC_DEFUN([CF_GXX_WARNINGS],
2556 [
2557
2558 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2559 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2560
2561 AC_REQUIRE([CF_GXX_VERSION])
2562
2563 AC_LANG_SAVE
2564 AC_LANG_CPLUSPLUS
2565
2566 cat > conftest.$ac_ext <<EOF
2567 #line __oline__ "configure"
2568 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2569 EOF
2570
2571 if test "$INTEL_CPLUSPLUS" = yes
2572 then
2573 # The "-wdXXX" options suppress warnings:
2574 # remark #1419: external declaration in primary source file
2575 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2576 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2577 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2578 # remark #193: zero used for undefined preprocessing identifier
2579 # remark #593: variable "curs_sb_left_arrow" was set but never used
2580 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2581 # remark #869: parameter "tw" was never referenced
2582 # remark #981: operands are evaluated in unspecified order
2583 # warning #269: invalid format string conversion
2584
2585         AC_CHECKING([for $CC warning options])
2586         cf_save_CXXFLAGS="$CXXFLAGS"
2587         EXTRA_CXXFLAGS="-Wall"
2588         for cf_opt in \
2589                 wd1419 \
2590                 wd1682 \
2591                 wd1683 \
2592                 wd1684 \
2593                 wd193 \
2594                 wd279 \
2595                 wd593 \
2596                 wd810 \
2597                 wd869 \
2598                 wd981
2599         do
2600                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2601                 if AC_TRY_EVAL(ac_compile); then
2602                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2603                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2604                 fi
2605         done
2606         CXXFLAGS="$cf_save_CXXFLAGS"
2607
2608 elif test "$GXX" = yes
2609 then
2610         AC_CHECKING([for $CXX warning options])
2611         cf_save_CXXFLAGS="$CXXFLAGS"
2612         EXTRA_CXXFLAGS="-W -Wall"
2613         cf_gxx_extra_warnings=""
2614         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2615         case "$GCC_VERSION" in
2616         [[1-2]].*)
2617                 ;;
2618         *)
2619                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2620                 ;;
2621         esac
2622         for cf_opt in \
2623                 Wabi \
2624                 fabi-version=0 \
2625                 Wextra \
2626                 Wignored-qualifiers \
2627                 Wlogical-op \
2628                 Woverloaded-virtual \
2629                 Wsign-promo \
2630                 Wsynth \
2631                 Wold-style-cast \
2632                 Wcast-align \
2633                 Wcast-qual \
2634                 Wpointer-arith \
2635                 Wshadow \
2636                 Wundef $cf_gxx_extra_warnings $1
2637         do
2638                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2639                 if AC_TRY_EVAL(ac_compile); then
2640                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2641                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2642                 else
2643                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2644                 fi
2645         done
2646         CXXFLAGS="$cf_save_CXXFLAGS"
2647 fi
2648
2649 rm -rf conftest*
2650 AC_LANG_RESTORE
2651 AC_SUBST(EXTRA_CXXFLAGS)
2652 ])dnl
2653 dnl ---------------------------------------------------------------------------
2654 dnl CF_HASHED_DB version: 5 updated: 2014/04/12 16:47:01
2655 dnl ------------
2656 dnl Look for an instance of the Berkeley hashed database.
2657 dnl
2658 dnl $1 = optional parameter, to specify install-prefix for the database.
2659 AC_DEFUN([CF_HASHED_DB],
2660 [
2661 ifelse([$1],,,[
2662 case $1 in #(vi
2663 yes|*able*) #(vi
2664     ;;
2665 *)
2666     if test -d "$1" ; then
2667         CF_ADD_INCDIR($1/include)
2668         CF_ADD_LIBDIR($1/lib)
2669         else
2670                 case "$1" in #(vi
2671                 ./*|../*|/*)
2672                         AC_MSG_WARN(no such directory $1)
2673                         ;; #(vi
2674                 *)
2675                         CF_FIND_SUB_INCDIR($1)
2676                         CF_FIND_SUB_LIBDIR($1)
2677                         ;;
2678                 esac
2679     fi
2680 esac
2681 ])
2682 AC_CHECK_HEADER(db.h,[
2683 CF_HASHED_DB_VERSION
2684 if test "$cf_cv_hashed_db_version" = unknown ; then
2685         AC_MSG_ERROR(Cannot determine version of db)
2686 else
2687         CF_HASHED_DB_LIBS
2688         if test "$cf_cv_hashed_db_libs" = unknown ; then
2689                 AC_MSG_ERROR(Cannot determine library for db)
2690         elif test "$cf_cv_hashed_db_libs" != default ; then
2691                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2692         fi
2693 fi
2694 ],[
2695         AC_MSG_ERROR(Cannot find db.h)
2696 ])
2697 ])dnl
2698 dnl ---------------------------------------------------------------------------
2699 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2700 dnl -----------------
2701 dnl Given that we have the header and version for hashed database, find the
2702 dnl library information.
2703 AC_DEFUN([CF_HASHED_DB_LIBS],
2704 [
2705 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2706 cf_cv_hashed_db_libs=unknown
2707 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2708 do
2709         cf_save_libs="$LIBS"
2710         if test -n "$cf_db_libs"; then
2711                 CF_ADD_LIB($cf_db_libs)
2712         fi
2713         CF_MSG_LOG(checking for library "$cf_db_libs")
2714         AC_TRY_LINK([
2715 $ac_includes_default
2716 #include <db.h>
2717 ],[
2718         char *path = "/tmp/foo";
2719 #ifdef DB_VERSION_MAJOR
2720 #if DB_VERSION_MAJOR >= 4
2721         DB *result = 0;
2722         db_create(&result, NULL, 0);
2723         result->open(result,
2724                 NULL,
2725                 path,
2726                 path,
2727                 DB_HASH,
2728                 DB_CREATE,
2729                 0644);
2730 #elif DB_VERSION_MAJOR >= 3
2731         DB *result = 0;
2732         db_create(&result, NULL, 0);
2733         result->open(result,
2734                 path,
2735                 path,
2736                 DB_HASH,
2737                 DB_CREATE,
2738                 0644);
2739 #elif DB_VERSION_MAJOR >= 2
2740         DB *result = 0;
2741         db_open(path,
2742                 DB_HASH,
2743                 DB_CREATE,
2744                 0644,
2745                 (DB_ENV *) 0,
2746                 (DB_INFO *) 0,
2747                 &result);
2748 #endif /* DB_VERSION_MAJOR */
2749 #else
2750         DB *result = dbopen(path,
2751                      2,
2752                      0644,
2753                      DB_HASH,
2754                      0);
2755 #endif
2756         ${cf_cv_main_return:-return}(result != 0)
2757 ],[
2758         if test -n "$cf_db_libs" ; then
2759                 cf_cv_hashed_db_libs=$cf_db_libs
2760         else
2761                 cf_cv_hashed_db_libs=default
2762         fi
2763         LIBS="$cf_save_libs"
2764         break
2765 ])
2766         LIBS="$cf_save_libs"
2767 done
2768 ])
2769 ])dnl
2770 dnl ---------------------------------------------------------------------------
2771 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
2772 dnl --------------------
2773 dnl Given that we have the header file for hashed database, find the version
2774 dnl information.
2775 AC_DEFUN([CF_HASHED_DB_VERSION],
2776 [
2777 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2778 cf_cv_hashed_db_version=unknown
2779
2780 for cf_db_version in 1 2 3 4 5 6
2781 do
2782         CF_MSG_LOG(checking for db version $cf_db_version)
2783         AC_TRY_COMPILE([
2784 $ac_includes_default
2785 #include <db.h>
2786
2787 #ifdef DB_VERSION_MAJOR
2788         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2789 #if $cf_db_version == DB_VERSION_MAJOR
2790         /* ok */
2791 #else
2792         make an error
2793 #endif
2794 #else
2795 #if $cf_db_version == 1
2796         /* ok: assuming this is DB 1.8.5 */
2797 #else
2798         make an error
2799 #endif
2800 #endif
2801 ],[DBT *foo = 0],[
2802         cf_cv_hashed_db_version=$cf_db_version
2803         break
2804         ])
2805 done
2806 ])
2807 ])dnl
2808 dnl ---------------------------------------------------------------------------
2809 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
2810 dnl --------------
2811 dnl Construct a search-list of directories for a nonstandard header-file
2812 dnl
2813 dnl Parameters
2814 dnl     $1 = the variable to return as result
2815 dnl     $2 = the package name
2816 AC_DEFUN([CF_HEADER_PATH],
2817 [
2818 $1=
2819
2820 # collect the current set of include-directories from compiler flags
2821 cf_header_path_list=""
2822 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2823         for cf_header_path in $CPPFLAGS $CFLAGS
2824         do
2825                 case $cf_header_path in #(vi
2826                 -I*)
2827                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2828                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2829                         cf_header_path_list="$cf_header_path_list [$]$1"
2830                         ;;
2831                 esac
2832         done
2833 fi
2834
2835 # add the variations for the package we are looking for
2836 CF_SUBDIR_PATH($1,$2,include)
2837
2838 test "$includedir" != NONE && \
2839 test "$includedir" != "/usr/include" && \
2840 test -d "$includedir" && {
2841         test -d $includedir &&    $1="[$]$1 $includedir"
2842         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2843 }
2844
2845 test "$oldincludedir" != NONE && \
2846 test "$oldincludedir" != "/usr/include" && \
2847 test -d "$oldincludedir" && {
2848         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2849         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2850 }
2851
2852 $1="[$]$1 $cf_header_path_list"
2853 ])dnl
2854 dnl ---------------------------------------------------------------------------
2855 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2856 dnl ---------------
2857 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2858 AC_DEFUN([CF_HELP_MESSAGE],
2859 [AC_DIVERT_HELP([$1])dnl
2860 ])dnl
2861 dnl ---------------------------------------------------------------------------
2862 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
2863 dnl ---------------
2864 dnl Construct the list of include-options according to whether we're building
2865 dnl in the source directory or using '--srcdir=DIR' option.
2866 AC_DEFUN([CF_INCLUDE_DIRS],
2867 [
2868 if test "$srcdir" != "."; then
2869         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
2870 fi
2871 CPPFLAGS="-I../include $CPPFLAGS"
2872 if test "$srcdir" != "."; then
2873         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
2874 fi
2875 CPPFLAGS="-I. $CPPFLAGS"
2876 AC_SUBST(CPPFLAGS)
2877 ])dnl
2878 dnl ---------------------------------------------------------------------------
2879 dnl CF_INTEL_COMPILER version: 6 updated: 2014/03/17 13:13:07
2880 dnl -----------------
2881 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2882 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2883 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2884 dnl
2885 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2886 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2887 dnl the wrappers for gcc and g++ warnings.
2888 dnl
2889 dnl $1 = GCC (default) or GXX
2890 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2891 dnl $3 = CFLAGS (default) or CXXFLAGS
2892 AC_DEFUN([CF_INTEL_COMPILER],[
2893 AC_REQUIRE([AC_CANONICAL_HOST])
2894 ifelse([$2],,INTEL_COMPILER,[$2])=no
2895
2896 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2897         case $host_os in
2898         linux*|gnu*)
2899                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2900                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2901                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2902                 AC_TRY_COMPILE([],[
2903 #ifdef __INTEL_COMPILER
2904 #else
2905 make an error
2906 #endif
2907 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2908 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
2909 ],[])
2910                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2911                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2912                 ;;
2913         esac
2914 fi
2915 ])dnl
2916 dnl ---------------------------------------------------------------------------
2917 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
2918 dnl ----------
2919 dnl Check if we have either a function or macro for 'isascii()'.
2920 AC_DEFUN([CF_ISASCII],
2921 [
2922 AC_MSG_CHECKING(for isascii)
2923 AC_CACHE_VAL(cf_cv_have_isascii,[
2924         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2925         [cf_cv_have_isascii=yes],
2926         [cf_cv_have_isascii=no])
2927 ])dnl
2928 AC_MSG_RESULT($cf_cv_have_isascii)
2929 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
2930 ])dnl
2931 dnl ---------------------------------------------------------------------------
2932 dnl CF_LARGEFILE version: 8 updated: 2012/10/06 08:57:51
2933 dnl ------------
2934 dnl Add checks for large file support.
2935 AC_DEFUN([CF_LARGEFILE],[
2936 ifdef([AC_FUNC_FSEEKO],[
2937     AC_SYS_LARGEFILE
2938     if test "$enable_largefile" != no ; then
2939         AC_FUNC_FSEEKO
2940
2941         # Normally we would collect these definitions in the config.h,
2942         # but (like _XOPEN_SOURCE), some environments rely on having these
2943         # defined before any of the system headers are included.  Another
2944         # case comes up with C++, e.g., on AIX the compiler compiles the
2945         # header files by themselves before looking at the body files it is
2946         # told to compile.  For ncurses, those header files do not include
2947         # the config.h
2948         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2949         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2950         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2951
2952         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2953                 AC_TRY_COMPILE([
2954 #include <sys/types.h>
2955 #include <dirent.h>
2956                 ],[
2957                 /* if transitional largefile support is setup, this is true */
2958                 extern struct dirent64 * readdir(DIR *);
2959                 struct dirent64 *x = readdir((DIR *)0);
2960                 struct dirent *y = readdir((DIR *)0);
2961                 int z = x - y;
2962                 ],
2963                 [cf_cv_struct_dirent64=yes],
2964                 [cf_cv_struct_dirent64=no])
2965         ])
2966         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
2967     fi
2968 ])
2969 ])
2970 dnl ---------------------------------------------------------------------------
2971 dnl CF_LDFLAGS_STATIC version: 10 updated: 2011/09/24 12:51:48
2972 dnl -----------------
2973 dnl Check for compiler/linker flags used to temporarily force usage of static
2974 dnl libraries.  This depends on the compiler and platform.  Use this to help
2975 dnl ensure that the linker picks up a given library based on its position in
2976 dnl the list of linker options and libraries.
2977 AC_DEFUN([CF_LDFLAGS_STATIC],[
2978
2979 if test "$GCC" = yes ; then
2980         case $cf_cv_system_name in #(
2981         OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)         #( vi
2982                 LDFLAGS_STATIC=
2983                 LDFLAGS_SHARED=
2984                 ;;
2985     *)  #( normally, except when broken
2986         LDFLAGS_STATIC=-static
2987         LDFLAGS_SHARED=-dynamic
2988         ;;
2989     esac
2990 else
2991         case $cf_cv_system_name in #(
2992         aix[[4-7]]*)    #( from ld manpage
2993                 LDFLAGS_STATIC=-bstatic
2994                 LDFLAGS_SHARED=-bdynamic
2995                 ;;
2996         hpux*)          #( from ld manpage for hpux10.20, hpux11.11
2997                 # We could also use just "archive" and "shared".
2998                 LDFLAGS_STATIC=-Wl,-a,archive_shared
2999                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3000                 ;;
3001         irix*)          #( from ld manpage IRIX64
3002                 LDFLAGS_STATIC=-Bstatic
3003                 LDFLAGS_SHARED=-Bdynamic
3004                 ;;
3005         osf[[45]]*)     #( from ld manpage osf4.0d, osf5.1
3006                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3007                 LDFLAGS_STATIC=-noso
3008                 LDFLAGS_SHARED=-so_archive
3009                 ;;
3010         solaris2*)
3011                 LDFLAGS_STATIC=-Bstatic
3012                 LDFLAGS_SHARED=-Bdynamic
3013                 ;;
3014         esac
3015 fi
3016
3017 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3018 then
3019         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3020
3021         rm -f libconftest.a
3022         cat >conftest.$ac_ext <<EOF
3023 #line __oline__ "configure"
3024 #include <stdio.h>
3025 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3026 EOF
3027         if AC_TRY_EVAL(ac_compile) ; then
3028                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3029                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3030         fi
3031         rm -f conftest.*
3032
3033         cf_save_LIBS="$LIBS"
3034
3035         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3036         AC_TRY_LINK([
3037 #line __oline__ "configure"
3038 #include <stdio.h>
3039 int cf_ldflags_static(FILE *fp);
3040 ],[
3041         return cf_ldflags_static(stdin);
3042 ],[
3043         # some linkers simply ignore the -dynamic
3044         case x`file conftest$ac_exeext 2>/dev/null` in #(vi
3045         *static*) # (vi
3046                 cf_ldflags_static=no
3047                 ;;
3048         *)
3049                 cf_ldflags_static=yes
3050                 ;;
3051         esac
3052 ],[cf_ldflags_static=no])
3053
3054         rm -f libconftest.*
3055         LIBS="$cf_save_LIBS"
3056
3057         AC_MSG_RESULT($cf_ldflags_static)
3058
3059         if test $cf_ldflags_static != yes
3060         then
3061                 LDFLAGS_STATIC=
3062                 LDFLAGS_SHARED=
3063         fi
3064 else
3065         LDFLAGS_STATIC=
3066         LDFLAGS_SHARED=
3067 fi
3068
3069 AC_SUBST(LDFLAGS_STATIC)
3070 AC_SUBST(LDFLAGS_SHARED)
3071 ])
3072 dnl ---------------------------------------------------------------------------
3073 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
3074 dnl ---------------
3075 dnl For the given system and compiler, find the compiler flags to pass to the
3076 dnl loader to use the "rpath" feature.
3077 AC_DEFUN([CF_LD_RPATH_OPT],
3078 [
3079 AC_REQUIRE([CF_CHECK_CACHE])
3080
3081 LD_RPATH_OPT=
3082 AC_MSG_CHECKING(for an rpath option)
3083 case $cf_cv_system_name in #(vi
3084 irix*) #(vi
3085         if test "$GCC" = yes; then
3086                 LD_RPATH_OPT="-Wl,-rpath,"
3087         else
3088                 LD_RPATH_OPT="-rpath "
3089         fi
3090         ;;
3091 linux*|gnu*|k*bsd*-gnu) #(vi
3092         LD_RPATH_OPT="-Wl,-rpath,"
3093         ;;
3094 openbsd[[2-9]].*|mirbsd*) #(vi
3095         LD_RPATH_OPT="-Wl,-rpath,"
3096         ;;
3097 dragonfly*|freebsd*) #(vi
3098         LD_RPATH_OPT="-rpath "
3099         ;;
3100 netbsd*) #(vi
3101         LD_RPATH_OPT="-Wl,-rpath,"
3102         ;;
3103 osf*|mls+*) #(vi
3104         LD_RPATH_OPT="-rpath "
3105         ;;
3106 solaris2*) #(vi
3107         LD_RPATH_OPT="-R"
3108         ;;
3109 *)
3110         ;;
3111 esac
3112 AC_MSG_RESULT($LD_RPATH_OPT)
3113
3114 case "x$LD_RPATH_OPT" in #(vi
3115 x-R*)
3116         AC_MSG_CHECKING(if we need a space after rpath option)
3117         cf_save_LIBS="$LIBS"
3118         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3119         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3120         LIBS="$cf_save_LIBS"
3121         AC_MSG_RESULT($cf_rpath_space)
3122         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3123         ;;
3124 esac
3125 ])dnl
3126 dnl ---------------------------------------------------------------------------
3127 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
3128 dnl ---------------
3129 dnl Construct a search-list of directories for a nonstandard library-file
3130 dnl
3131 dnl Parameters
3132 dnl     $1 = the variable to return as result
3133 dnl     $2 = the package name
3134 AC_DEFUN([CF_LIBRARY_PATH],
3135 [
3136 $1=
3137 cf_library_path_list=""
3138 if test -n "${LDFLAGS}${LIBS}" ; then
3139         for cf_library_path in $LDFLAGS $LIBS
3140         do
3141                 case $cf_library_path in #(vi
3142                 -L*)
3143                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3144                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3145                         cf_library_path_list="$cf_library_path_list [$]$1"
3146                         ;;
3147                 esac
3148         done
3149 fi
3150
3151 CF_SUBDIR_PATH($1,$2,lib)
3152
3153 $1="$cf_library_path_list [$]$1"
3154 ])dnl
3155 dnl ---------------------------------------------------------------------------
3156 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3157 dnl ------------------
3158 AC_DEFUN([CF_LIBTOOL_VERSION],[
3159 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3160 then
3161         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3162 else
3163         cf_cv_libtool_version=
3164 fi
3165 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3166 ])dnl
3167 dnl ---------------------------------------------------------------------------
3168 dnl CF_LIB_PREFIX version: 9 updated: 2012/01/21 19:28:10
3169 dnl -------------
3170 dnl Compute the library-prefix for the given host system
3171 dnl $1 = variable to set
3172 define([CF_LIB_PREFIX],
3173 [
3174         case $cf_cv_system_name in #(vi
3175         OS/2*|os2*) #(vi
3176         LIB_PREFIX=''
3177         ;;
3178         *)      LIB_PREFIX='lib'
3179         ;;
3180         esac
3181 ifelse($1,,,[$1=$LIB_PREFIX])
3182         AC_SUBST(LIB_PREFIX)
3183 ])dnl
3184 dnl ---------------------------------------------------------------------------
3185 dnl CF_LIB_RULES version: 75 updated: 2014/09/20 20:16:32
3186 dnl ------------
3187 dnl Append definitions and rules for the given models to the subdirectory
3188 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3189 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3190 dnl the corresponding makefile to list the models that we'll generate.
3191 dnl
3192 dnl For shared libraries, make a list of symbolic links to construct when
3193 dnl generating each library.  The convention used for Linux is the simplest
3194 dnl one:
3195 dnl     lib<name>.so    ->
3196 dnl     lib<name>.so.<major>    ->
3197 dnl     lib<name>.so.<maj>.<minor>
3198 dnl
3199 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3200 AC_DEFUN([CF_LIB_RULES],
3201 [
3202 cf_prefix=$LIB_PREFIX
3203 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3204
3205 case $cf_cv_shlib_version in #(vi
3206 cygdll|msysdll|mingw)
3207         TINFO_NAME=$TINFO_ARG_SUFFIX
3208         TINFO_SUFFIX=.dll
3209         ;;
3210 esac
3211
3212 if test -n "$TINFO_SUFFIX" ; then
3213         case $TINFO_SUFFIX in
3214         tw*)
3215                 TINFO_NAME="${TINFO_NAME}tw"
3216                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw//'`
3217                 ;;
3218         t*)
3219                 TINFO_NAME="${TINFO_NAME}t"
3220                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t//'`
3221                 ;;
3222         w*)
3223                 TINFO_NAME="${TINFO_NAME}w"
3224                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w//'`
3225                 ;;
3226         esac
3227 fi
3228
3229 for cf_dir in $SRC_SUBDIRS
3230 do
3231         if test ! -d $srcdir/$cf_dir ; then
3232                 continue
3233         elif test -f $srcdir/$cf_dir/modules; then
3234
3235                 SHARED_LIB=
3236                 Libs_To_Make=
3237                 for cf_item in $cf_LIST_MODELS
3238                 do
3239                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3240                         cf_libname=$cf_dir
3241                         test "$cf_dir" = c++ && cf_libname=ncurses++
3242                         if test $cf_item = shared ; then
3243                                 if test -n "${LIB_SUFFIX}"
3244                                 then
3245                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${LIB_SUFFIX}"'//'`
3246                                 else
3247                                         cf_shared_suffix="$cf_suffix"
3248                                 fi
3249                                 if test "$cf_cv_do_symlinks" = yes ; then
3250                                         cf_version_name=
3251
3252                                         case "$cf_cv_shlib_version" in #(vi
3253                                         rel) #(vi
3254                                                 cf_version_name=REL_VERSION
3255                                                 ;;
3256                                         abi)
3257                                                 cf_version_name=ABI_VERSION
3258                                                 ;;
3259                                         esac
3260
3261                                         if test -n "$cf_version_name"
3262                                         then
3263                                                 case "$cf_cv_system_name" in #(vi
3264                                                 darwin*)
3265                                                         # "w", etc?
3266                                                         cf_suffix="${LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3267                                                         ;; #(vi
3268                                                 *)
3269                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3270                                                         ;;
3271                                                 esac
3272                                         fi
3273                                         if test -n "${LIB_SUFFIX}"
3274                                         then
3275                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${LIB_SUFFIX}"'//'`
3276                                         else
3277                                                 cf_shared_suffix="$cf_suffix"
3278                                         fi
3279                                 fi
3280                                 # cygwin needs import library, and has unique naming convention
3281                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3282                                 # use 'cyg' prefix for shared lib.
3283                                 case $cf_cv_shlib_version in #(vi
3284                                 cygdll) #(vi
3285                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3286                                         Libs_To_Make="$Libs_To_Make ../lib/cyg${cf_libname}${cf_cygsuf}"
3287                                         continue
3288                                         ;;
3289                                 msysdll) #(vi
3290                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3291                                         Libs_To_Make="$Libs_To_Make ../lib/msys-${cf_libname}${cf_cygsuf}"
3292                                         continue
3293                                         ;;
3294                                 mingw)
3295                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3296                                         Libs_To_Make="$Libs_To_Make ../lib/lib${cf_libname}${cf_cygsuf}"
3297                                         continue
3298                                         ;;
3299                                 esac
3300                         fi
3301                         Libs_To_Make="$Libs_To_Make ../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3302                 done
3303
3304                 if test $cf_dir = ncurses ; then
3305                         cf_subsets="$LIB_SUBSETS"
3306                         cf_r_parts="$cf_subsets"
3307                         cf_liblist="$Libs_To_Make"
3308
3309                         while test -n "$cf_r_parts"
3310                         do
3311                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3312                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3313                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3314                                         cf_item=
3315                                         case $cf_l_parts in #(vi
3316                                         *termlib*) #(vi
3317                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3318                                                 ;;
3319                                         *ticlib*)
3320                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3321                                                 ;;
3322                                         *)
3323                                                 break
3324                                                 ;;
3325                                         esac
3326                                         if test -n "$cf_item"; then
3327                                                 Libs_To_Make="$cf_item $Libs_To_Make"
3328                                         fi
3329                                 else
3330                                         break
3331                                 fi
3332                         done
3333                 else
3334                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3335                 fi
3336
3337                 if test $cf_dir = c++; then
3338                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3339                                 cf_list=
3340                                 for cf_item in $Libs_To_Make
3341                                 do
3342                                         case $cf_item in
3343                                         *.a)
3344                                                 ;;
3345                                         *)
3346                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3347                                                 ;;
3348                                         esac
3349                                         for cf_test in $cf_list
3350                                         do
3351                                                 if test "$cf_test" = "$cf_item"
3352                                                 then
3353                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3354                                                         cf_item=
3355                                                         break
3356                                                 fi
3357                                         done
3358                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3359                                 done
3360                                 Libs_To_Make="$cf_list"
3361                         fi
3362                 fi
3363
3364                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3365                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3366                         $cf_dir/Makefile >$cf_dir/Makefile.out
3367                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3368
3369                 $AWK -f $srcdir/mk-0th.awk \
3370                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3371                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3372
3373                 for cf_subset in $cf_subsets
3374                 do
3375                         cf_subdirs=
3376                         for cf_item in $cf_LIST_MODELS
3377                         do
3378
3379                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3380                         CF_UPPER(cf_ITEM,$cf_item)
3381
3382                         CXX_MODEL=$cf_ITEM
3383                         if test "$CXX_MODEL" = SHARED; then
3384                                 case $cf_cv_shlib_version in #(vi
3385                                 cygdll|msysdll|mingw) #(vi
3386                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3387                                         with_shared_cxx=yes
3388                                         ;;
3389                                 *)
3390                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3391                                         ;;
3392                                 esac
3393                         fi
3394
3395                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3396                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3397
3398                         # Test for case where we build libtinfo with a different name.
3399                         cf_libname=$cf_dir
3400                         if test $cf_dir = ncurses ; then
3401                                 case $cf_subset in
3402                                 *base*)
3403                                         cf_libname=${cf_libname}$LIB_SUFFIX
3404                                         ;;
3405                                 *termlib*)
3406                                         cf_libname=$TINFO_LIB_SUFFIX
3407                                         ;;
3408                                 ticlib*)
3409                                         cf_libname=$TICS_LIB_SUFFIX
3410                                         ;;
3411                                 esac
3412                         elif test $cf_dir = c++ ; then
3413                                 cf_libname=ncurses++$LIB_SUFFIX
3414                         else
3415                                 cf_libname=${cf_libname}$LIB_SUFFIX
3416                         fi
3417                         if test -n "${DFT_ARG_SUFFIX}" ; then
3418                                 # undo $LIB_SUFFIX add-on in CF_LIB_SUFFIX
3419                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${LIB_SUFFIX}%%"`
3420                         fi
3421
3422                         # These dependencies really are for development, not
3423                         # builds, but they are useful in porting, too.
3424                         cf_depend="../include/ncurses_cfg.h"
3425                         if test "$srcdir" = "."; then
3426                                 cf_reldir="."
3427                         else
3428                                 cf_reldir="\${srcdir}"
3429                         fi
3430
3431                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3432                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3433                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3434                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3435                         fi
3436
3437                         cf_dir_suffix=
3438                         old_cf_suffix="$cf_suffix"
3439                         if test "$cf_cv_shlib_version_infix" = yes ; then
3440                         if test -n "$LIB_SUFFIX" ; then
3441                                 case $LIB_SUFFIX in
3442                                 tw*)
3443                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
3444                                         cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3445                                         cf_dir_suffix=tw
3446                                         ;;
3447                                 t*)
3448                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
3449                                         cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3450                                         cf_dir_suffix=t
3451                                         ;;
3452                                 w*)
3453                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
3454                                         cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3455                                         cf_dir_suffix=w
3456                                         ;;
3457                                 esac
3458                         fi
3459                         fi
3460
3461                         $AWK -f $srcdir/mk-1st.awk \
3462                                 name=${cf_libname}${cf_dir_suffix} \
3463                                 traces=$LIB_TRACING \
3464                                 MODEL=$cf_ITEM \
3465                                 CXX_MODEL=$CXX_MODEL \
3466                                 model=$cf_subdir \
3467                                 prefix=$cf_prefix \
3468                                 suffix=$cf_suffix \
3469                                 subset=$cf_subset \
3470                                 driver=$cf_cv_term_driver \
3471                                 SymLink="$LN_S" \
3472                                 TermlibRoot=$TINFO_NAME \
3473                                 TermlibSuffix=$TINFO_SUFFIX \
3474                                 ShlibVer=$cf_cv_shlib_version \
3475                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3476                                 ReLink=${cf_cv_do_relink:-no} \
3477                                 DoLinks=$cf_cv_do_symlinks \
3478                                 rmSoLocs=$cf_cv_rm_so_locs \
3479                                 ldconfig="$LDCONFIG" \
3480                                 overwrite=$WITH_OVERWRITE \
3481                                 depend="$cf_depend" \
3482                                 host="$host" \
3483                                 libtool_version="$LIBTOOL_VERSION" \
3484                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3485
3486                         cf_suffix="$old_cf_suffix"
3487
3488                         for cf_subdir2 in $cf_subdirs lib
3489                         do
3490                                 test $cf_subdir = $cf_subdir2 && break
3491                         done
3492                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3493                         $AWK -f $srcdir/mk-2nd.awk \
3494                                 name=$cf_dir \
3495                                 traces=$LIB_TRACING \
3496                                 MODEL=$cf_ITEM \
3497                                 model=$cf_subdir \
3498                                 subset=$cf_subset \
3499                                 srcdir=$srcdir \
3500                                 echo=$WITH_ECHO \
3501                                 crenames=$cf_cv_prog_CC_c_o \
3502                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3503                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3504                         cf_subdirs="$cf_subdirs $cf_subdir"
3505                         done
3506                 done
3507         fi
3508
3509         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
3510 done
3511
3512 for cf_dir in $SRC_SUBDIRS
3513 do
3514         if test ! -d $srcdir/$cf_dir ; then
3515                 continue
3516         fi
3517
3518         if test -f $cf_dir/Makefile ; then
3519                 case "$cf_dir" in
3520                 Ada95) #(vi
3521                         echo 'libs \' >> Makefile
3522                         echo 'install.libs \' >> Makefile
3523                         echo 'uninstall.libs ::' >> Makefile
3524                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
3525                         ;;
3526                 esac
3527         fi
3528
3529         if test -f $srcdir/$cf_dir/modules; then
3530                 echo >> Makefile
3531                 if test -f $srcdir/$cf_dir/headers; then
3532 cat >> Makefile <<CF_EOF
3533 install.includes \\
3534 uninstall.includes \\
3535 CF_EOF
3536                 fi
3537 if test "$cf_dir" != "c++" ; then
3538 echo 'lint \' >> Makefile
3539 fi
3540 cat >> Makefile <<CF_EOF
3541 libs \\
3542 lintlib \\
3543 install.libs \\
3544 uninstall.libs \\
3545 install.$cf_dir \\
3546 uninstall.$cf_dir ::
3547         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3548 CF_EOF
3549         elif test -f $srcdir/$cf_dir/headers; then
3550 cat >> Makefile <<CF_EOF
3551
3552 libs \\
3553 install.libs \\
3554 uninstall.libs \\
3555 install.includes \\
3556 uninstall.includes ::
3557         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3558 CF_EOF
3559 fi
3560 done
3561
3562 if test "x$cf_with_db_install" = xyes; then
3563 cat >> Makefile <<CF_EOF
3564
3565 install.libs uninstall.libs \\
3566 install.data uninstall.data ::
3567 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3568 CF_EOF
3569 else
3570 cat >> Makefile <<CF_EOF
3571
3572 install.libs uninstall.libs ::
3573         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3574 CF_EOF
3575 fi
3576
3577 if test "x$cf_with_manpages" = xyes; then
3578 cat >> Makefile <<CF_EOF
3579
3580 install.man \\
3581 uninstall.man ::
3582         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
3583 CF_EOF
3584 fi
3585
3586 cat >> Makefile <<CF_EOF
3587
3588 distclean ::
3589         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3590         rm -f headers.sh headers.sed mk_shared_lib.sh
3591         rm -f edit_man.* man_alias.*
3592         rm -rf \${DIRS_TO_MAKE}
3593 CF_EOF
3594
3595 # Special case: tack's manpage lives in its own directory.
3596 if test "x$cf_with_manpages" = xyes; then
3597 if test -d tack ; then
3598 if test -f $srcdir/$tack.h; then
3599 cat >> Makefile <<CF_EOF
3600
3601 install.man \\
3602 uninstall.man ::
3603         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
3604 CF_EOF
3605 fi
3606 fi
3607 fi
3608
3609 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3610 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3611 dnl anything, and will make it more standardized.  It's awkward to decide this
3612 dnl at configuration because of quoting, so we'll simply make all headers
3613 dnl installed via a script that can do the right thing.
3614
3615 rm -f headers.sed headers.sh
3616
3617 dnl ( generating this script makes the makefiles a little tidier :-)
3618 echo creating headers.sh
3619 cat >headers.sh <<CF_EOF
3620 #! /bin/sh
3621 # This shell script is generated by the 'configure' script.  It is invoked in a
3622 # subdirectory of the build tree.  It generates a sed-script in the parent
3623 # directory that is used to adjust includes for header files that reside in a
3624 # subdirectory of /usr/include, etc.
3625 PRG=""
3626 while test \[$]# != 3
3627 do
3628 PRG="\$PRG \[$]1"; shift
3629 done
3630 DST=\[$]1
3631 REF=\[$]2
3632 SRC=\[$]3
3633 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3634 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3635 echo installing \$SRC in \$DST
3636 CF_EOF
3637
3638 if test $WITH_CURSES_H = yes; then
3639         cat >>headers.sh <<CF_EOF
3640 case \$DST in
3641 /*/include/*)
3642         END=\`basename \$DST\`
3643         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3644         do
3645                 NAME=\`basename \$i\`
3646                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3647         done
3648         ;;
3649 *)
3650         echo "" >> \$TMPSED
3651         ;;
3652 esac
3653 CF_EOF
3654
3655 else
3656         cat >>headers.sh <<CF_EOF
3657 case \$DST in
3658 /*/include/*)
3659         END=\`basename \$DST\`
3660         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3661         do
3662                 NAME=\`basename \$i\`
3663                 if test "\$NAME" = "curses.h"
3664                 then
3665                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3666                         NAME=ncurses.h
3667                 fi
3668                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3669         done
3670         ;;
3671 *)
3672         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3673         ;;
3674 esac
3675 CF_EOF
3676 fi
3677 cat >>headers.sh <<CF_EOF
3678 rm -f \$TMPSRC
3679 sed -f \$TMPSED \$SRC > \$TMPSRC
3680 NAME=\`basename \$SRC\`
3681 CF_EOF
3682 if test $WITH_CURSES_H != yes; then
3683         cat >>headers.sh <<CF_EOF
3684 test "\$NAME" = "curses.h" && NAME=ncurses.h
3685 CF_EOF
3686 fi
3687 cat >>headers.sh <<CF_EOF
3688 # Just in case someone gzip'd manpages, remove the conflicting copy.
3689 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3690
3691 eval \$PRG \$TMPSRC \$DST/\$NAME
3692 rm -f \$TMPSRC \$TMPSED
3693 CF_EOF
3694
3695 chmod 0755 headers.sh
3696
3697 for cf_dir in $SRC_SUBDIRS
3698 do
3699         if test ! -d $srcdir/$cf_dir ; then
3700                 continue
3701         fi
3702
3703         if test -f $srcdir/$cf_dir/headers; then
3704                 $AWK -f $srcdir/mk-hdr.awk \
3705                         subset="$LIB_SUBSETS" \
3706                         compat="$WITH_CURSES_H" \
3707                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3708         fi
3709
3710         if test -f $srcdir/$cf_dir/modules; then
3711                 if test "$cf_dir" != "c++" ; then
3712                         cat >>$cf_dir/Makefile <<"CF_EOF"
3713 depend : ${AUTO_SRC}
3714         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3715
3716 # DO NOT DELETE THIS LINE -- make depend depends on it.
3717 CF_EOF
3718                 fi
3719         fi
3720 done