aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2013,2014 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.692 2014/05/24 21:24:50 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 3 updated: 2002/10/27 23:21:42
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54     [AC_TRY_LINK([#include <langinfo.h>],
  55       [char* cs = nl_langinfo(CODESET);],
  56       am_cv_langinfo_codeset=yes,
  57       am_cv_langinfo_codeset=no)
  58     ])
  59   if test $am_cv_langinfo_codeset = yes; then
  60     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62   fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ACVERSION_CHECK version: 4 updated: 2013/03/04 19:52:56
  66 dnl ------------------
  67 dnl Conditionally generate script according to whether we're using a given autoconf.
  68 dnl
  69 dnl $1 = version to compare against
  70 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  71 dnl $3 = code to use if AC_ACVERSION is older than $1.
  72 define([CF_ACVERSION_CHECK],
  73 [
  74 ifdef([AC_ACVERSION], ,[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])dnl
  75 ifdef([m4_version_compare],
  76 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  77 [CF_ACVERSION_COMPARE(
  78 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  79 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  80 dnl ---------------------------------------------------------------------------
  81 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  82 dnl --------------------
  83 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  84 dnl                      MAJOR2, MINOR2, TERNARY2,
  85 dnl                      PRINTABLE2, not FOUND, FOUND)
  86 define([CF_ACVERSION_COMPARE],
  87 [ifelse(builtin([eval], [$2 < $5]), 1,
  88 [ifelse([$8], , ,[$8])],
  89 [ifelse([$9], , ,[$9])])])dnl
  90 dnl ---------------------------------------------------------------------------
  91 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
  92 dnl -------------------
  93 dnl Construct the list of include-options for the C programs in the Ada95
  94 dnl binding.
  95 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  96 [
  97 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  98 if test "$srcdir" != "."; then
  99         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 100 fi
 101 if test "$GCC" != yes; then
 102         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 103 elif test "$includedir" != "/usr/include"; then
 104         if test "$includedir" = '${prefix}/include' ; then
 105                 if test x$prefix != x/usr ; then
 106                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 107                 fi
 108         else
 109                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 110         fi
 111 fi
 112 AC_SUBST(ACPPFLAGS)
 113 ])dnl
 114 dnl ---------------------------------------------------------------------------
 115 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 116 dnl ---------------
 117 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 118 AC_DEFUN([CF_ADD_ADAFLAGS],[
 119         ADAFLAGS="$ADAFLAGS $1"
 120         AC_SUBST(ADAFLAGS)
 121 ])dnl
 122 dnl ---------------------------------------------------------------------------
 123 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
 124 dnl -------------
 125 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 126 dnl The second parameter if given makes this macro verbose.
 127 dnl
 128 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 129 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 130 dnl confused by the quotes (which require backslashes to keep them usable).
 131 AC_DEFUN([CF_ADD_CFLAGS],
 132 [
 133 cf_fix_cppflags=no
 134 cf_new_cflags=
 135 cf_new_cppflags=
 136 cf_new_extra_cppflags=
 137
 138 for cf_add_cflags in $1
 139 do
 140 case $cf_fix_cppflags in
 141 no)
 142         case $cf_add_cflags in #(vi
 143         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
 144                 case $cf_add_cflags in
 145                 -D*)
 146                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 147
 148                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 149                                 && test -z "${cf_tst_cflags}" \
 150                                 && cf_fix_cppflags=yes
 151
 152                         if test $cf_fix_cppflags = yes ; then
 153                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 154                                 continue
 155                         elif test "${cf_tst_cflags}" = "\"'" ; then
 156                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 157                                 continue
 158                         fi
 159                         ;;
 160                 esac
 161                 case "$CPPFLAGS" in
 162                 *$cf_add_cflags) #(vi
 163                         ;;
 164                 *) #(vi
 165                         case $cf_add_cflags in #(vi
 166                         -D*)
 167                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 168                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 169                                 ;;
 170                         esac
 171                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 172                         ;;
 173                 esac
 174                 ;;
 175         *)
 176                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 177                 ;;
 178         esac
 179         ;;
 180 yes)
 181         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 182
 183         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 184
 185         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 186                 && test -z "${cf_tst_cflags}" \
 187                 && cf_fix_cppflags=no
 188         ;;
 189 esac
 190 done
 191
 192 if test -n "$cf_new_cflags" ; then
 193         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 194         CFLAGS="$CFLAGS $cf_new_cflags"
 195 fi
 196
 197 if test -n "$cf_new_cppflags" ; then
 198         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 199         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 200 fi
 201
 202 if test -n "$cf_new_extra_cppflags" ; then
 203         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 204         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 205 fi
 206
 207 AC_SUBST(EXTRA_CPPFLAGS)
 208
 209 ])dnl
 210 dnl ---------------------------------------------------------------------------
 211 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 212 dnl -------------
 213 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 214 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 215 dnl but old versions (and some misinstalled ones) need that.  To make things
 216 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 217 dnl the include-path).
 218 AC_DEFUN([CF_ADD_INCDIR],
 219 [
 220 if test -n "$1" ; then
 221   for cf_add_incdir in $1
 222   do
 223         while test $cf_add_incdir != /usr/include
 224         do
 225           if test -d $cf_add_incdir
 226           then
 227                 cf_have_incdir=no
 228                 if test -n "$CFLAGS$CPPFLAGS" ; then
 229                   # a loop is needed to ensure we can add subdirs of existing dirs
 230                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 231                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 232                           cf_have_incdir=yes; break
 233                         fi
 234                   done
 235                 fi
 236
 237                 if test "$cf_have_incdir" = no ; then
 238                   if test "$cf_add_incdir" = /usr/local/include ; then
 239                         if test "$GCC" = yes
 240                         then
 241                           cf_save_CPPFLAGS=$CPPFLAGS
 242                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 243                           AC_TRY_COMPILE([#include <stdio.h>],
 244                                   [printf("Hello")],
 245                                   [],
 246                                   [cf_have_incdir=yes])
 247                           CPPFLAGS=$cf_save_CPPFLAGS
 248                         fi
 249                   fi
 250                 fi
 251
 252                 if test "$cf_have_incdir" = no ; then
 253                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 254                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 255
 256                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 257                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 258                   cf_add_incdir="$cf_top_incdir"
 259                 else
 260                   break
 261                 fi
 262           fi
 263         done
 264   done
 265 fi
 266 ])dnl
 267 dnl ---------------------------------------------------------------------------
 268 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 269 dnl ----------
 270 dnl Add a library, used to enforce consistency.
 271 dnl
 272 dnl $1 = library to add, without the "-l"
 273 dnl $2 = variable to update (default $LIBS)
 274 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 275 dnl ---------------------------------------------------------------------------
 276 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 277 dnl -------------
 278 dnl     Adds to the library-path
 279 dnl
 280 dnl     Some machines have trouble with multiple -L options.
 281 dnl
 282 dnl $1 is the (list of) directory(s) to add
 283 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 284 dnl
 285 AC_DEFUN([CF_ADD_LIBDIR],
 286 [
 287 if test -n "$1" ; then
 288   for cf_add_libdir in $1
 289   do
 290     if test $cf_add_libdir = /usr/lib ; then
 291       :
 292     elif test -d $cf_add_libdir
 293     then
 294       cf_have_libdir=no
 295       if test -n "$LDFLAGS$LIBS" ; then
 296         # a loop is needed to ensure we can add subdirs of existing dirs
 297         for cf_test_libdir in $LDFLAGS $LIBS ; do
 298           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 299             cf_have_libdir=yes; break
 300           fi
 301         done
 302       fi
 303       if test "$cf_have_libdir" = no ; then
 304         CF_VERBOSE(adding $cf_add_libdir to library-path)
 305         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 306       fi
 307     fi
 308   done
 309 fi
 310 ])dnl
 311 dnl ---------------------------------------------------------------------------
 312 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 313 dnl -----------
 314 dnl Add one or more libraries, used to enforce consistency.
 315 dnl
 316 dnl $1 = libraries to add, with the "-l", etc.
 317 dnl $2 = variable to update (default $LIBS)
 318 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 319 dnl ---------------------------------------------------------------------------
 320 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 321 dnl ------------------
 322 dnl Append to a search-list for a nonstandard header/lib-file
 323 dnl     $1 = the variable to return as result
 324 dnl     $2 = the package name
 325 dnl     $3 = the subdirectory, e.g., bin, include or lib
 326 dnl $4 = the directory under which we will test for subdirectories
 327 dnl $5 = a directory that we do not want $4 to match
 328 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 329 [
 330 test "x$4" != "x$5" && \
 331 test -d "$4" && \
 332 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 333         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 334         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 335         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 336         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 337         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 338         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 339 }
 340 ])dnl
 341 dnl ---------------------------------------------------------------------------
 342 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 343 dnl --------------
 344 dnl Allow user to disable a normally-on option.
 345 AC_DEFUN([CF_ARG_DISABLE],
 346 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 347 dnl ---------------------------------------------------------------------------
 348 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 349 dnl -------------
 350 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 351 dnl values.
 352 dnl
 353 dnl Parameters:
 354 dnl $1 = option name
 355 dnl $2 = help-string
 356 dnl $3 = action to perform if option is not default
 357 dnl $4 = action if perform if option is default
 358 dnl $5 = default option value (either 'yes' or 'no')
 359 AC_DEFUN([CF_ARG_OPTION],
 360 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 361   if test "$enableval" != "$5" ; then
 362 ifelse([$3],,[    :]dnl
 363 ,[    $3]) ifelse([$4],,,[
 364   else
 365     $4])
 366   fi],[enableval=$5 ifelse([$4],,,[
 367   $4
 368 ])dnl
 369   ])])dnl
 370 dnl ---------------------------------------------------------------------------
 371 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 372 dnl -----------
 373 dnl Check for suitable "ar" (archiver) options for updating an archive.
 374 AC_DEFUN([CF_AR_FLAGS],[
 375 AC_REQUIRE([CF_PROG_AR])
 376
 377 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 378         cf_cv_ar_flags=unknown
 379         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 380         do
 381
 382                 # check if $ARFLAGS already contains this choice
 383                 if test "x$ARFLAGS" != "x" ; then
 384                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 385                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 386                                 cf_cv_ar_flags=
 387                                 break
 388                         fi
 389                 fi
 390
 391                 rm -f conftest.$ac_cv_objext
 392                 rm -f conftest.a
 393
 394                 cat >conftest.$ac_ext <<EOF
 395 #line __oline__ "configure"
 396 int     testdata[[3]] = { 123, 456, 789 };
 397 EOF
 398                 if AC_TRY_EVAL(ac_compile) ; then
 399                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 400                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 401                         if test -f conftest.a ; then
 402                                 cf_cv_ar_flags=$cf_ar_flags
 403                                 break
 404                         fi
 405                 else
 406                         CF_VERBOSE(cannot compile test-program)
 407                         break
 408                 fi
 409         done
 410         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 411 ])
 412
 413 if test -n "$ARFLAGS" ; then
 414         if test -n "$cf_cv_ar_flags" ; then
 415                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 416         fi
 417 else
 418         ARFLAGS=$cf_cv_ar_flags
 419 fi
 420
 421 AC_SUBST(ARFLAGS)
 422 ])
 423 dnl ---------------------------------------------------------------------------
 424 dnl CF_AWK_BIG_PRINTF version: 4 updated: 2011/10/30 17:09:50
 425 dnl -----------------
 426 dnl Check if awk can handle big strings using printf.  Some older versions of
 427 dnl awk choke on large strings passed via "%s".
 428 dnl
 429 dnl $1 = desired string size
 430 dnl $2 = variable to set with result
 431 AC_DEFUN([CF_AWK_BIG_PRINTF],
 432 [
 433         case x$AWK in #(vi
 434         x)
 435                 eval $2=no
 436                 ;;
 437         *) #(vi
 438                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 439                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 440                         eval $2=yes
 441                 else
 442                         eval $2=no
 443                 fi
 444                 ;;
 445         esac
 446 ])dnl
 447 dnl ---------------------------------------------------------------------------
 448 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 449 dnl ------------
 450 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 451 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 452 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 453 dnl
 454 dnl Treat the configuration-variable specially here, since we're directly
 455 dnl substituting its value (i.e., 1/0).
 456 dnl
 457 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 458 AC_DEFUN([CF_BOOL_DECL],
 459 [
 460 AC_MSG_CHECKING(if we should include stdbool.h)
 461
 462 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 463         AC_TRY_COMPILE([],[bool foo = false],
 464                 [cf_cv_header_stdbool_h=0],
 465                 [AC_TRY_COMPILE([
 466 #ifndef __BEOS__
 467 #include <stdbool.h>
 468 #endif
 469 ],[bool foo = false],
 470                         [cf_cv_header_stdbool_h=1],
 471                         [cf_cv_header_stdbool_h=0])])])
 472
 473 if test "$cf_cv_header_stdbool_h" = 1
 474 then    AC_MSG_RESULT(yes)
 475 else    AC_MSG_RESULT(no)
 476 fi
 477
 478 AC_MSG_CHECKING([for builtin bool type])
 479
 480 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 481         AC_TRY_COMPILE([
 482 #include <stdio.h>
 483 #include <sys/types.h>
 484 ],[bool x = false],
 485                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 486                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 487         ])
 488
 489 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 490 then    AC_MSG_RESULT(yes)
 491 else    AC_MSG_RESULT(no)
 492 fi
 493 ])dnl
 494 dnl ---------------------------------------------------------------------------
 495 dnl CF_BOOL_SIZE version: 13 updated: 2013/04/13 18:03:21
 496 dnl ------------
 497 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 498 dnl Don't bother looking for bool.h, since it's been deprecated.
 499 dnl
 500 dnl If the current compiler is C rather than C++, we get the bool definition
 501 dnl from <stdbool.h>.
 502 AC_DEFUN([CF_BOOL_SIZE],
 503 [
 504 AC_MSG_CHECKING([for size of bool])
 505 AC_CACHE_VAL(cf_cv_type_of_bool,[
 506         rm -f cf_test.out
 507         AC_TRY_RUN([
 508 #include <stdlib.h>
 509 #include <stdio.h>
 510
 511 #if defined(__cplusplus)
 512
 513 #ifdef HAVE_GXX_BUILTIN_H
 514 #include <g++/builtin.h>
 515 #elif HAVE_GPP_BUILTIN_H
 516 #include <gpp/builtin.h>
 517 #elif HAVE_BUILTIN_H
 518 #include <builtin.h>
 519 #endif
 520
 521 #else
 522
 523 #if $cf_cv_header_stdbool_h
 524 #include <stdbool.h>
 525 #endif
 526
 527 #endif
 528
 529 int main()
 530 {
 531         FILE *fp = fopen("cf_test.out", "w");
 532         if (fp != 0) {
 533                 bool x = true;
 534                 if ((bool)(-x) >= 0)
 535                         fputs("unsigned ", fp);
 536                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 537                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 538                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 539                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 540                 fclose(fp);
 541         }
 542         ${cf_cv_main_return:-return}(0);
 543 }
 544                 ],
 545                 [cf_cv_type_of_bool=`cat cf_test.out`
 546                  if test -z "$cf_cv_type_of_bool"; then
 547                    cf_cv_type_of_bool=unknown
 548                  fi],
 549                 [cf_cv_type_of_bool=unknown],
 550                 [cf_cv_type_of_bool=unknown])
 551         ])
 552         rm -f cf_test.out
 553 AC_MSG_RESULT($cf_cv_type_of_bool)
 554 if test "$cf_cv_type_of_bool" = unknown ; then
 555         case .$NCURSES_BOOL in #(vi
 556         .auto|.) NCURSES_BOOL=unsigned;;
 557         esac
 558         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 559         cf_cv_type_of_bool=$NCURSES_BOOL
 560 fi
 561 ])dnl
 562 dnl ---------------------------------------------------------------------------
 563 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 564 dnl -----------
 565 dnl If we're cross-compiling, allow the user to override the tools and their
 566 dnl options.  The configure script is oriented toward identifying the host
 567 dnl compiler, etc., but we need a build compiler to generate parts of the
 568 dnl source.
 569 dnl
 570 dnl $1 = default for $CPPFLAGS
 571 dnl $2 = default for $LIBS
 572 AC_DEFUN([CF_BUILD_CC],[
 573 CF_ACVERSION_CHECK(2.52,,
 574         [AC_REQUIRE([CF_PROG_EXT])])
 575 if test "$cross_compiling" = yes ; then
 576
 577         # defaults that we might want to override
 578         : ${BUILD_CFLAGS:=''}
 579         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 580         : ${BUILD_LDFLAGS:=''}
 581         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 582         : ${BUILD_EXEEXT:='$x'}
 583         : ${BUILD_OBJEXT:='o'}
 584
 585         AC_ARG_WITH(build-cc,
 586                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 587                 [BUILD_CC="$withval"],
 588                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 589         AC_MSG_CHECKING(for native build C compiler)
 590         AC_MSG_RESULT($BUILD_CC)
 591
 592         AC_MSG_CHECKING(for native build C preprocessor)
 593         AC_ARG_WITH(build-cpp,
 594                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 595                 [BUILD_CPP="$withval"],
 596                 [BUILD_CPP='${BUILD_CC} -E'])
 597         AC_MSG_RESULT($BUILD_CPP)
 598
 599         AC_MSG_CHECKING(for native build C flags)
 600         AC_ARG_WITH(build-cflags,
 601                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 602                 [BUILD_CFLAGS="$withval"])
 603         AC_MSG_RESULT($BUILD_CFLAGS)
 604
 605         AC_MSG_CHECKING(for native build C preprocessor-flags)
 606         AC_ARG_WITH(build-cppflags,
 607                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 608                 [BUILD_CPPFLAGS="$withval"])
 609         AC_MSG_RESULT($BUILD_CPPFLAGS)
 610
 611         AC_MSG_CHECKING(for native build linker-flags)
 612         AC_ARG_WITH(build-ldflags,
 613                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 614                 [BUILD_LDFLAGS="$withval"])
 615         AC_MSG_RESULT($BUILD_LDFLAGS)
 616
 617         AC_MSG_CHECKING(for native build linker-libraries)
 618         AC_ARG_WITH(build-libs,
 619                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 620                 [BUILD_LIBS="$withval"])
 621         AC_MSG_RESULT($BUILD_LIBS)
 622
 623         # this assumes we're on Unix.
 624         BUILD_EXEEXT=
 625         BUILD_OBJEXT=o
 626
 627         : ${BUILD_CC:='${CC}'}
 628
 629         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 630                 AC_MSG_ERROR([Cross-build requires two compilers.
 631 Use --with-build-cc to specify the native compiler.])
 632         fi
 633
 634 else
 635         : ${BUILD_CC:='${CC}'}
 636         : ${BUILD_CPP:='${CPP}'}
 637         : ${BUILD_CFLAGS:='${CFLAGS}'}
 638         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 639         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 640         : ${BUILD_LIBS:='${LIBS}'}
 641         : ${BUILD_EXEEXT:='$x'}
 642         : ${BUILD_OBJEXT:='o'}
 643 fi
 644
 645 AC_SUBST(BUILD_CC)
 646 AC_SUBST(BUILD_CPP)
 647 AC_SUBST(BUILD_CFLAGS)
 648 AC_SUBST(BUILD_CPPFLAGS)
 649 AC_SUBST(BUILD_LDFLAGS)
 650 AC_SUBST(BUILD_LIBS)
 651 AC_SUBST(BUILD_EXEEXT)
 652 AC_SUBST(BUILD_OBJEXT)
 653 ])dnl
 654 dnl ---------------------------------------------------------------------------
 655 dnl CF_CC_ENV_FLAGS version: 1 updated: 2012/10/03 05:25:49
 656 dnl ---------------
 657 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 658 dnl into CC.  This will not help with broken scripts that wrap the compiler with
 659 dnl options, but eliminates a more common category of user confusion.
 660 AC_DEFUN([CF_CC_ENV_FLAGS],
 661 [
 662 # This should have been defined by AC_PROG_CC
 663 : ${CC:=cc}
 664
 665 AC_MSG_CHECKING(\$CC variable)
 666 case "$CC" in #(vi
 667 *[[\ \  ]]-[[IUD]]*)
 668         AC_MSG_RESULT(broken)
 669         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 670         # humor him...
 671         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 672         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 673         CF_ADD_CFLAGS($cf_flags)
 674         ;;
 675 *)
 676         AC_MSG_RESULT(ok)
 677         ;;
 678 esac
 679 ])dnl
 680 dnl ---------------------------------------------------------------------------
 681 dnl CF_CFG_DEFAULTS version: 10 updated: 2013/09/07 13:54:05
 682 dnl ---------------
 683 dnl Determine the default configuration into which we'll install ncurses.  This
 684 dnl can be overridden by the user's command-line options.  There's two items to
 685 dnl look for:
 686 dnl     1. the prefix (e.g., /usr)
 687 dnl     2. the header files (e.g., /usr/include/ncurses)
 688 dnl We'll look for a previous installation of ncurses and use the same defaults.
 689 dnl
 690 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 691 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 692 dnl programs from a vendor's.
 693 AC_DEFUN([CF_CFG_DEFAULTS],
 694 [
 695 AC_MSG_CHECKING(for prefix)
 696 if test "x$prefix" = "xNONE" ; then
 697         case "$cf_cv_system_name" in
 698                 # non-vendor systems don't have a conflict
 699         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 700                 prefix=/usr
 701                 ;;
 702         *)      prefix=$ac_default_prefix
 703                 ;;
 704         esac
 705 fi
 706 AC_MSG_RESULT($prefix)
 707
 708 if test "x$prefix" = "xNONE" ; then
 709 AC_MSG_CHECKING(for default include-directory)
 710 test -n "$verbose" && echo 1>&AC_FD_MSG
 711 for cf_symbol in \
 712         $includedir \
 713         $includedir/ncurses \
 714         $prefix/include \
 715         $prefix/include/ncurses \
 716         /usr/local/include \
 717         /usr/local/include/ncurses \
 718         /usr/include \
 719         /usr/include/ncurses
 720 do
 721         cf_dir=`eval echo $cf_symbol`
 722         if test -f $cf_dir/curses.h ; then
 723         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 724                 includedir="$cf_symbol"
 725                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 726                 break
 727         fi
 728         fi
 729         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 730 done
 731 AC_MSG_RESULT($includedir)
 732 fi
 733 ])dnl
 734 dnl ---------------------------------------------------------------------------
 735 dnl CF_CGETENT version: 5 updated: 2012/10/06 17:56:13
 736 dnl ----------
 737 dnl Check if the terminal-capability database functions are available.  If not,
 738 dnl ncurses has a much-reduced version.
 739 AC_DEFUN([CF_CGETENT],[
 740 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 741 AC_TRY_LINK([
 742 #include <stdlib.h>],[
 743         char temp[128];
 744         char *buf = temp;
 745         char *db_array = temp;
 746         cgetent(&buf, &db_array, "vt100");
 747         cgetcap(buf, "tc", '=');
 748         cgetmatch(buf, "tc");
 749         ],
 750         [cf_cv_cgetent=yes],
 751         [cf_cv_cgetent=no])
 752 ])
 753
 754 if test "$cf_cv_cgetent" = yes
 755 then
 756         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 757 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 758 AC_TRY_LINK([
 759 #include <stdlib.h>],[
 760         char temp[128];
 761         char *buf = temp;
 762 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 763         const char *db_array = temp;
 764         cgetent(&buf, &db_array, "vt100");
 765 #endif
 766         cgetcap(buf, "tc", '=');
 767         cgetmatch(buf, "tc");
 768         ],
 769         [cf_cv_cgetent_const=yes],
 770         [cf_cv_cgetent_const=no])
 771 ])
 772         if test "$cf_cv_cgetent_const" = yes
 773         then
 774                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 775         fi
 776 fi
 777 ])dnl
 778 dnl ---------------------------------------------------------------------------
 779 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 780 dnl --------------
 781 dnl Check if we're accidentally using a cache from a different machine.
 782 dnl Derive the system name, as a check for reusing the autoconf cache.
 783 dnl
 784 dnl If we've packaged config.guess and config.sub, run that (since it does a
 785 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 786 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 787 dnl which is useful in cross-compiles.
 788 dnl
 789 dnl Note: we would use $ac_config_sub, but that is one of the places where
 790 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 791 AC_DEFUN([CF_CHECK_CACHE],
 792 [
 793 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 794         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 795         system_name="$host_os"
 796 else
 797         system_name="`(uname -s -r) 2>/dev/null`"
 798         if test -z "$system_name" ; then
 799                 system_name="`(hostname) 2>/dev/null`"
 800         fi
 801 fi
 802 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 803 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 804
 805 test -z "$system_name" && system_name="$cf_cv_system_name"
 806 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 807
 808 if test ".$system_name" != ".$cf_cv_system_name" ; then
 809         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 810         AC_MSG_ERROR("Please remove config.cache and try again.")
 811 fi
 812 ])dnl
 813 dnl ---------------------------------------------------------------------------
 814 dnl CF_CHECK_ERRNO version: 11 updated: 2010/05/26 05:38:42
 815 dnl --------------
 816 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 817 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 818 dnl ourselves.
 819 dnl
 820 dnl $1 = the name to check
 821 dnl $2 = the assumed type
 822 AC_DEFUN([CF_CHECK_ERRNO],
 823 [
 824 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 825     AC_TRY_COMPILE([
 826 #ifdef HAVE_STDLIB_H
 827 #include <stdlib.h>
 828 #endif
 829 #include <stdio.h>
 830 #include <sys/types.h>
 831 #include <errno.h> ],
 832     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 833     [cf_cv_dcl_$1=yes],
 834     [cf_cv_dcl_$1=no])
 835 ])
 836
 837 if test "$cf_cv_dcl_$1" = no ; then
 838     CF_UPPER(cf_result,decl_$1)
 839     AC_DEFINE_UNQUOTED($cf_result)
 840 fi
 841
 842 # It's possible (for near-UNIX clones) that the data doesn't exist
 843 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 844 ])dnl
 845 dnl ---------------------------------------------------------------------------
 846 dnl CF_CHECK_EXTERN_DATA version: 3 updated: 2001/12/30 18:03:23
 847 dnl --------------------
 848 dnl Check for existence of external data in the current set of libraries.  If
 849 dnl we can modify it, it's real enough.
 850 dnl $1 = the name to check
 851 dnl $2 = its type
 852 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 853 [
 854 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 855     AC_TRY_LINK([
 856 #undef $1
 857 extern $2 $1;
 858 ],
 859     [$1 = 2],
 860     [cf_cv_have_$1=yes],
 861     [cf_cv_have_$1=no])
 862 ])
 863
 864 if test "$cf_cv_have_$1" = yes ; then
 865     CF_UPPER(cf_result,have_$1)
 866     AC_DEFINE_UNQUOTED($cf_result)
 867 fi
 868
 869 ])dnl
 870 dnl ---------------------------------------------------------------------------
 871 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 872 dnl -------------------
 873 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 874 dnl is not "weak" - warn about this because it can create problems linking
 875 dnl applications with ncurses.
 876 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 877 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 878
 879 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 880 cf_cv_check_gpm_wgetch=unknown
 881 if test "$cross_compiling" != yes ; then
 882
 883 cat >conftest.$ac_ext <<CF_EOF
 884 #include <gpm.h>
 885 int main()
 886 {
 887         Gpm_Wgetch();
 888         ${cf_cv_main_return:-return}(0);
 889 }
 890 CF_EOF
 891
 892         cf_save_LIBS="$LIBS"
 893         # This only works if we can look at the symbol table.  If a shared
 894         # library is stripped for install, we cannot use that.  So we're forced
 895         # to rely on the static library, noting that some packagers may not
 896         # include it.
 897         LIBS="-static -lgpm -dynamic $LIBS"
 898         if AC_TRY_EVAL(ac_compile) ; then
 899                 if AC_TRY_EVAL(ac_link) ; then
 900                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 901                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 902                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 903                 fi
 904         fi
 905         rm -rf conftest*
 906         LIBS="$cf_save_LIBS"
 907 fi
 908 ])
 909
 910 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 911         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 912 fi
 913 ])])dnl
 914 dnl ---------------------------------------------------------------------------
 915 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
 916 dnl ------------------------
 917 dnl Show the version of libtool
 918 dnl
 919 dnl Save the version in a cache variable - this is not entirely a good thing,
 920 dnl but the version string from libtool is very ugly, and for bug reports it
 921 dnl might be useful to have the original string.
 922 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
 923 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
 924 then
 925         AC_MSG_CHECKING(version of $LIBTOOL)
 926         CF_LIBTOOL_VERSION
 927         AC_MSG_RESULT($cf_cv_libtool_version)
 928         if test -z "$cf_cv_libtool_version" ; then
 929                 AC_MSG_ERROR(This is not GNU libtool)
 930         fi
 931 else
 932         AC_MSG_ERROR(GNU libtool has not been found)
 933 fi
 934 ])dnl
 935 dnl ---------------------------------------------------------------------------
 936 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
 937 dnl ----------------
 938 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
 939 AC_DEFUN([CF_CHECK_WCHAR_H],[
 940 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
 941 AC_TRY_COMPILE(
 942 [
 943 #include <stdlib.h>
 944 #include <wchar.h>
 945 ],[
 946         wint_t foo = 0;
 947         int bar = iswpunct(foo)],
 948         [cf_cv_wchar_h_okay=yes],
 949         [cf_cv_wchar_h_okay=no])])
 950
 951 if test $cf_cv_wchar_h_okay = no
 952 then
 953         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 954 fi
 955 ])dnl
 956 dnl ---------------------------------------------------------------------------
 957 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
 958 dnl -----------------
 959 dnl Check if the given compiler is really clang.  clang's C driver defines
 960 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 961 dnl not ignore some gcc options.
 962 dnl
 963 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 964 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 965 dnl the wrappers for gcc and g++ warnings.
 966 dnl
 967 dnl $1 = GCC (default) or GXX
 968 dnl $2 = CLANG_COMPILER (default)
 969 dnl $3 = CFLAGS (default) or CXXFLAGS
 970 AC_DEFUN([CF_CLANG_COMPILER],[
 971 ifelse([$2],,CLANG_COMPILER,[$2])=no
 972
 973 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 974         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 975         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 976         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
 977         AC_TRY_COMPILE([],[
 978 #ifdef __clang__
 979 #else
 980 make an error
 981 #endif
 982 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 983 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
 984 ],[])
 985         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 986         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 987 fi
 988 ])
 989 dnl ---------------------------------------------------------------------------
 990 dnl CF_CPP_PARAM_INIT version: 6 updated: 2012/10/06 17:56:13
 991 dnl -----------------
 992 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
 993 dnl is a late feature for the standard and is not in some recent compilers
 994 dnl (1999/9/11).
 995 AC_DEFUN([CF_CPP_PARAM_INIT],
 996 [
 997 if test -n "$CXX"; then
 998 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
 999         AC_LANG_SAVE
1000         AC_LANG_CPLUSPLUS
1001         AC_TRY_RUN([
1002 class TEST {
1003 private:
1004         int value;
1005 public:
1006         TEST(int x = 1);
1007         ~TEST();
1008 };
1009
1010 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1011 {
1012         value = x;
1013 }
1014 int main() { }
1015 ],
1016         [cf_cv_cpp_param_init=yes],
1017         [cf_cv_cpp_param_init=no],
1018         [cf_cv_cpp_param_init=unknown])
1019         AC_LANG_RESTORE
1020 ])
1021 fi
1022 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1023 ])dnl
1024 dnl ---------------------------------------------------------------------------
1025 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1026 dnl ------------------
1027 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1028 dnl not be supported in g++ before 3.0
1029 AC_DEFUN([CF_CPP_STATIC_CAST],
1030 [
1031 if test -n "$CXX"; then
1032
1033 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1034         AC_LANG_SAVE
1035         AC_LANG_CPLUSPLUS
1036
1037         AC_TRY_COMPILE([
1038 class NCursesPanel
1039 {
1040 public:
1041   NCursesPanel(int nlines,
1042                int ncols,
1043                int begin_y = 0,
1044                int begin_x = 0)
1045   {
1046   }
1047   NCursesPanel();
1048   ~NCursesPanel();
1049 };
1050
1051 template<class T> class NCursesUserPanel : public NCursesPanel
1052 {
1053 public:
1054   NCursesUserPanel (int nlines,
1055                     int ncols,
1056                     int begin_y = 0,
1057                     int begin_x = 0,
1058                     const T* p_UserData = static_cast<T*>(0))
1059     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1060   {
1061   };
1062   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1063   {
1064   };
1065
1066   virtual ~NCursesUserPanel() {};
1067 };
1068 ],[
1069         const char* p_UserData = static_cast<char*>(0)],
1070         [cf_cv_cpp_static_cast=yes],
1071         [cf_cv_cpp_static_cast=no])
1072
1073         AC_LANG_RESTORE
1074 ])
1075
1076 fi
1077
1078 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1079 ])dnl
1080 dnl ---------------------------------------------------------------------------
1081 dnl CF_CXX_AR_FLAGS version: 1 updated: 2011/10/29 08:35:34
1082 dnl ---------------
1083 dnl Setup special archiver flags for given compilers.
1084 AC_DEFUN([CF_CXX_AR_FLAGS],[
1085         CXX_AR='$(AR)'
1086         CXX_ARFLAGS='$(ARFLAGS)'
1087         case $cf_cv_system_name in #(vi
1088         irix*) #(vi
1089             if test "$GXX" != yes ; then
1090                 CXX_AR='$(CXX)'
1091                 CXX_ARFLAGS='-ar -o'
1092             fi
1093             ;;
1094         sco3.2v5*) #(vi
1095             CXXLDFLAGS="-u main"
1096             ;;
1097         solaris2*)
1098             if test "$GXX" != yes ; then
1099                 CXX_AR='$(CXX)'
1100                 CXX_ARFLAGS='-xar -o'
1101             fi
1102             ;;
1103         esac
1104         AC_SUBST(CXXLDFLAGS)
1105         AC_SUBST(CXX_AR)
1106         AC_SUBST(CXX_ARFLAGS)
1107 ])dnl
1108 dnl ---------------------------------------------------------------------------
1109 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1110 dnl -------------------------
1111 dnl For c++, check if iostream uses "std::" namespace.
1112 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1113 AC_CHECK_HEADERS(iostream)
1114 if test x"$ac_cv_header_iostream" = xyes ; then
1115         AC_MSG_CHECKING(if iostream uses std-namespace)
1116         AC_TRY_COMPILE([
1117 #include <iostream>
1118 using std::endl;
1119 using std::cerr;],[
1120 cerr << "testing" << endl;
1121 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1122         AC_MSG_RESULT($cf_iostream_namespace)
1123         if test "$cf_iostream_namespace" = yes ; then
1124                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1125         fi
1126 fi
1127 ])dnl
1128 dnl ---------------------------------------------------------------------------
1129 dnl CF_C_INLINE version: 4 updated: 2012/06/16 14:55:39
1130 dnl -----------
1131 dnl Check if the C compiler supports "inline".
1132 dnl $1 is the name of a shell variable to set if inline is supported
1133 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1134 AC_DEFUN([CF_C_INLINE],[
1135 AC_C_INLINE
1136 $1=
1137 if test "$ac_cv_c_inline" != no ; then
1138   $1=inline
1139   if test "$INTEL_COMPILER" = yes
1140   then
1141     :
1142   elif test "$CLANG_COMPILER" = yes
1143   then
1144     :
1145   elif test "$GCC" = yes
1146   then
1147     AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1148       cf_save_CFLAGS=$CFLAGS
1149       CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1150       AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1151       [${cf_cv_main_return:-return} foo()],
1152       [cf_cv_gcc_inline=yes],
1153       [cf_cv_gcc_inline=no])
1154       CFLAGS=$cf_save_CFLAGS
1155     ])
1156     if test "$cf_cv_gcc_inline" = yes ; then
1157         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1158     fi
1159   fi
1160 fi
1161 AC_SUBST($1)
1162 ])dnl
1163 dnl ---------------------------------------------------------------------------
1164 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1165 dnl ----------
1166 dnl "dirname" is not portable, so we fake it with a shell script.
1167 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1168 dnl ---------------------------------------------------------------------------
1169 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1170 dnl ---------------
1171 AC_DEFUN([CF_DIRS_TO_MAKE],
1172 [
1173 DIRS_TO_MAKE="lib"
1174 for cf_item in $cf_list_models
1175 do
1176         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1177         for cf_item2 in $DIRS_TO_MAKE
1178         do
1179                 test $cf_item2 = $cf_subdir && break
1180         done
1181         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1182 done
1183 for cf_dir in $DIRS_TO_MAKE
1184 do
1185         test ! -d $cf_dir && mkdir $cf_dir
1186 done
1187 AC_SUBST(DIRS_TO_MAKE)
1188 ])dnl
1189 dnl ---------------------------------------------------------------------------
1190 dnl CF_DISABLE_ECHO version: 12 updated: 2012/10/06 16:30:28
1191 dnl ---------------
1192 dnl You can always use "make -n" to see the actual options, but it's hard to
1193 dnl pick out/analyze warning messages when the compile-line is long.
1194 dnl
1195 dnl Sets:
1196 dnl     ECHO_LT - symbol to control if libtool is verbose
1197 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1198 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1199 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1200 dnl     ECHO_CC - symbol to put before any "cc" line
1201 dnl
1202 AC_DEFUN([CF_DISABLE_ECHO],[
1203 AC_MSG_CHECKING(if you want to see long compiling messages)
1204 CF_ARG_DISABLE(echo,
1205         [  --disable-echo          do not display "compiling" commands],
1206         [
1207     ECHO_LT='--silent'
1208     ECHO_LD='@echo linking [$]@;'
1209     RULE_CC='@echo compiling [$]<'
1210     SHOW_CC='@echo compiling [$]@'
1211     ECHO_CC='@'
1212 ],[
1213     ECHO_LT=''
1214     ECHO_LD=''
1215     RULE_CC=''
1216     SHOW_CC=''
1217     ECHO_CC=''
1218 ])
1219 AC_MSG_RESULT($enableval)
1220 AC_SUBST(ECHO_LT)
1221 AC_SUBST(ECHO_LD)
1222 AC_SUBST(RULE_CC)
1223 AC_SUBST(SHOW_CC)
1224 AC_SUBST(ECHO_CC)
1225 ])dnl
1226 dnl ---------------------------------------------------------------------------
1227 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1228 dnl ----------------
1229 dnl Combine no-leak checks with the libraries or tools that are used for the
1230 dnl checks.
1231 AC_DEFUN([CF_DISABLE_LEAKS],[
1232
1233 AC_REQUIRE([CF_WITH_DMALLOC])
1234 AC_REQUIRE([CF_WITH_DBMALLOC])
1235 AC_REQUIRE([CF_WITH_VALGRIND])
1236
1237 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1238 AC_ARG_ENABLE(leaks,
1239         [  --disable-leaks         test: free permanent memory, analyze leaks],
1240         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1241         : ${with_no_leaks:=no})
1242 AC_MSG_RESULT($with_no_leaks)
1243
1244 if test "$with_no_leaks" = yes ; then
1245         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1246         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1247 fi
1248 ])dnl
1249 dnl ---------------------------------------------------------------------------
1250 dnl CF_DISABLE_LIBTOOL_VERSION version: 1 updated: 2010/05/15 15:45:59
1251 dnl --------------------------
1252 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1253 dnl the older "-version-info" feature.  The newer feature allows us to use
1254 dnl version numbering on shared libraries which make them compatible with
1255 dnl various systems.
1256 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1257 [
1258 AC_MSG_CHECKING(if libtool -version-number should be used)
1259 CF_ARG_DISABLE(libtool-version,
1260         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1261         [cf_libtool_version=no],
1262         [cf_libtool_version=yes])
1263 AC_MSG_RESULT($cf_libtool_version)
1264
1265 if test "$cf_libtool_version" = yes ; then
1266         LIBTOOL_VERSION="-version-number"
1267 else
1268         LIBTOOL_VERSION="-version-info"
1269 fi
1270
1271 AC_SUBST(LIBTOOL_VERSION)
1272 ])dnl
1273 dnl ---------------------------------------------------------------------------
1274 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1275 dnl ---------------------
1276 dnl The rpath-hack makes it simpler to build programs, particularly with the
1277 dnl *BSD ports which may have essential libraries in unusual places.  But it
1278 dnl can interfere with building an executable for the base system.  Use this
1279 dnl option in that case.
1280 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1281 [
1282 AC_MSG_CHECKING(if rpath-hack should be disabled)
1283 CF_ARG_DISABLE(rpath-hack,
1284         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1285         [cf_disable_rpath_hack=yes],
1286         [cf_disable_rpath_hack=no])
1287 AC_MSG_RESULT($cf_disable_rpath_hack)
1288 if test "$cf_disable_rpath_hack" = no ; then
1289         CF_RPATH_HACK
1290 fi
1291 ])
1292 dnl ---------------------------------------------------------------------------
1293 dnl CF_ENABLE_PC_FILES version: 9 updated: 2012/08/04 13:59:54
1294 dnl ------------------
1295 dnl This is the "--enable-pc-files" option, which is available if there is a
1296 dnl pkg-config configuration on the local machine.
1297 AC_DEFUN([CF_ENABLE_PC_FILES],[
1298 AC_REQUIRE([CF_PKG_CONFIG])
1299 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1300
1301 if test "$PKG_CONFIG" != none ; then
1302         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1303         AC_ARG_ENABLE(pc-files,
1304                 [  --enable-pc-files       generate and install .pc files for pkg-config],
1305                 [enable_pc_files=$enableval],
1306                 [enable_pc_files=no])
1307         AC_MSG_RESULT($enable_pc_files)
1308         if test "$enable_pc_files" != no
1309         then
1310                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1311         fi
1312 else
1313         enable_pc_files=no
1314 fi
1315 ])dnl
1316 dnl ---------------------------------------------------------------------------
1317 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1318 dnl ---------------
1319 dnl Check if the rpath option should be used, setting cache variable
1320 dnl cf_cv_enable_rpath if so.
1321 AC_DEFUN([CF_ENABLE_RPATH],
1322 [
1323 AC_MSG_CHECKING(if rpath option should be used)
1324 AC_ARG_ENABLE(rpath,
1325 [  --enable-rpath          use rpath option when generating shared libraries],
1326 [cf_cv_enable_rpath=$enableval],
1327 [cf_cv_enable_rpath=no])
1328 AC_MSG_RESULT($cf_cv_enable_rpath)
1329 ])dnl
1330 dnl ---------------------------------------------------------------------------
1331 dnl CF_ENABLE_STRING_HACKS version: 3 updated: 2013/01/26 16:26:12
1332 dnl ----------------------
1333 dnl On a few platforms, the compiler and/or loader nags with untruthful
1334 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1335 dnl and implying that most uses of the recommended alternatives are correct.
1336 dnl
1337 dnl Factually speaking, no one has actually counted the number of uses of these
1338 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1339 dnl instances are meaningless compared to the hundreds of millions of lines of
1340 dnl existing C code.
1341 dnl
1342 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1343 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1344 dnl standard - but evolved through phases, and older implementations are likely
1345 dnl to yield surprising results, as documented in manpages on various systems.
1346 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1347 [
1348 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1349 AC_ARG_ENABLE(string-hacks,
1350         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1351         [with_string_hacks=$enableval],
1352         [with_string_hacks=no])
1353 AC_MSG_RESULT($with_string_hacks)
1354
1355 if test "x$with_string_hacks" = "xyes"; then
1356         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1357         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1358         AC_CHECK_FUNCS( strlcat strlcpy snprintf )
1359 fi
1360 ])dnl
1361 dnl ---------------------------------------------------------------------------
1362 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1363 dnl --------
1364 dnl Check if 'errno' is declared in <errno.h>
1365 AC_DEFUN([CF_ERRNO],
1366 [
1367 CF_CHECK_ERRNO(errno)
1368 ])dnl
1369 dnl ---------------------------------------------------------------------------
1370 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1371 dnl ---------------
1372 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1373 dnl math.h and builtin.h, only for ncurses
1374 AC_DEFUN([CF_ETIP_DEFINES],
1375 [
1376 AC_MSG_CHECKING(for special defines needed for etip.h)
1377 cf_save_CXXFLAGS="$CXXFLAGS"
1378 cf_result="none"
1379
1380 # etip.h includes ncurses.h which includes ncurses_dll.h
1381 # But ncurses_dll.h is generated - fix here.
1382 test -d include || mkdir include
1383 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1384
1385 for cf_math in "" MATH_H
1386 do
1387 for cf_excp in "" MATH_EXCEPTION
1388 do
1389         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1390         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1391         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1392 AC_TRY_COMPILE([
1393 #include <etip.h.in>
1394 ],[],[
1395         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1396         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1397         cf_result="$cf_math $cf_excp"
1398         break 2
1399 ],[])
1400 done
1401 done
1402 AC_MSG_RESULT($cf_result)
1403 CXXFLAGS="$cf_save_CXXFLAGS"
1404 ])
1405 dnl ---------------------------------------------------------------------------
1406 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1407 dnl ---------------
1408 dnl Find a library (specifically the linkage used in the code fragment),
1409 dnl searching for it if it is not already in the library path.
1410 dnl See also CF_ADD_SEARCHPATH.
1411 dnl
1412 dnl Parameters (4-on are optional):
1413 dnl     $1 = headers for library entrypoint
1414 dnl     $2 = code fragment for library entrypoint
1415 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1416 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1417 dnl     $5 = action to perform if not successful
1418 dnl     $6 = module name, if not the same as the library name
1419 dnl     $7 = extra libraries
1420 dnl
1421 dnl Sets these variables:
1422 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1423 dnl     $cf_cv_header_path_$3 - include-directory if needed
1424 dnl     $cf_cv_library_path_$3 - library-directory if needed
1425 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1426 AC_DEFUN([CF_FIND_LINKAGE],[
1427
1428 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1429 # will be set on completion of the AC_TRY_LINK below.
1430 cf_cv_header_path_$3=
1431 cf_cv_library_path_$3=
1432
1433 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1434
1435 cf_save_LIBS="$LIBS"
1436
1437 AC_TRY_LINK([$1],[$2],[
1438         cf_cv_find_linkage_$3=yes
1439         cf_cv_header_path_$3=/usr/include
1440         cf_cv_library_path_$3=/usr/lib
1441 ],[
1442
1443 LIBS="-l$3 $7 $cf_save_LIBS"
1444
1445 AC_TRY_LINK([$1],[$2],[
1446         cf_cv_find_linkage_$3=yes
1447         cf_cv_header_path_$3=/usr/include
1448         cf_cv_library_path_$3=/usr/lib
1449         cf_cv_library_file_$3="-l$3"
1450 ],[
1451         cf_cv_find_linkage_$3=no
1452         LIBS="$cf_save_LIBS"
1453
1454     CF_VERBOSE(find linkage for $3 library)
1455     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1456
1457     cf_save_CPPFLAGS="$CPPFLAGS"
1458     cf_test_CPPFLAGS="$CPPFLAGS"
1459
1460     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1461     for cf_cv_header_path_$3 in $cf_search
1462     do
1463       if test -d $cf_cv_header_path_$3 ; then
1464         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1465         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1466         AC_TRY_COMPILE([$1],[$2],[
1467             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1468             cf_cv_find_linkage_$3=maybe
1469             cf_test_CPPFLAGS="$CPPFLAGS"
1470             break],[
1471             CPPFLAGS="$cf_save_CPPFLAGS"
1472             ])
1473       fi
1474     done
1475
1476     if test "$cf_cv_find_linkage_$3" = maybe ; then
1477
1478       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1479
1480       cf_save_LIBS="$LIBS"
1481       cf_save_LDFLAGS="$LDFLAGS"
1482
1483       ifelse([$6],,,[
1484         CPPFLAGS="$cf_test_CPPFLAGS"
1485         LIBS="-l$3 $7 $cf_save_LIBS"
1486         AC_TRY_LINK([$1],[$2],[
1487             CF_VERBOSE(... found $3 library in system)
1488             cf_cv_find_linkage_$3=yes])
1489             CPPFLAGS="$cf_save_CPPFLAGS"
1490             LIBS="$cf_save_LIBS"
1491             ])
1492
1493       if test "$cf_cv_find_linkage_$3" != yes ; then
1494         CF_LIBRARY_PATH(cf_search,$3)
1495         for cf_cv_library_path_$3 in $cf_search
1496         do
1497           if test -d $cf_cv_library_path_$3 ; then
1498             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1499             CPPFLAGS="$cf_test_CPPFLAGS"
1500             LIBS="-l$3 $7 $cf_save_LIBS"
1501             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1502             AC_TRY_LINK([$1],[$2],[
1503                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1504                 cf_cv_find_linkage_$3=yes
1505                 cf_cv_library_file_$3="-l$3"
1506                 break],[
1507                 CPPFLAGS="$cf_save_CPPFLAGS"
1508                 LIBS="$cf_save_LIBS"
1509                 LDFLAGS="$cf_save_LDFLAGS"
1510                 ])
1511           fi
1512         done
1513         CPPFLAGS="$cf_save_CPPFLAGS"
1514         LDFLAGS="$cf_save_LDFLAGS"
1515       fi
1516
1517     else
1518       cf_cv_find_linkage_$3=no
1519     fi
1520     ],$7)
1521 ])
1522
1523 LIBS="$cf_save_LIBS"
1524
1525 if test "$cf_cv_find_linkage_$3" = yes ; then
1526 ifelse([$4],,[
1527         CF_ADD_INCDIR($cf_cv_header_path_$3)
1528         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1529         CF_ADD_LIB($3)
1530 ],[$4])
1531 else
1532 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1533 fi
1534 ])dnl
1535 dnl ---------------------------------------------------------------------------
1536 dnl CF_FIND_SUB_INCDIR version: 1 updated: 2014/04/12 16:47:01
1537 dnl ------------------
1538 dnl Find an include-directory with the given leaf-name.  This is useful for
1539 dnl example with FreeBSD ports, which use this convention to distinguish
1540 dnl different versions of the same port.
1541 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1542         CF_SUBDIR_PATH(cf_search,$1,include)
1543         for cf_item in $cf_search
1544         do
1545                 case $cf_item in #(vi
1546                 */$1)
1547                         CF_ADD_INCDIR($cf_item)
1548                         ;;
1549                 esac
1550         done
1551 ])dnl
1552 dnl ---------------------------------------------------------------------------
1553 dnl CF_FIND_SUB_LIBDIR version: 1 updated: 2014/04/12 16:47:01
1554 dnl ------------------
1555 dnl Find a library-directory with the given leaf-name.  This is useful for
1556 dnl example with FreeBSD ports, which use this convention to distinguish
1557 dnl different versions of the same port.
1558 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1559         CF_SUBDIR_PATH(cf_search,$1,lib)
1560         for cf_item in $cf_search
1561         do
1562                 case $cf_item in #(vi
1563                 */$1)
1564                         CF_ADD_LIBDIR($cf_item)
1565                         ;;
1566                 esac
1567         done
1568 ])dnl
1569 dnl ---------------------------------------------------------------------------
1570 dnl CF_FIXUP_ADAFLAGS version: 1 updated: 2012/03/31 18:48:10
1571 dnl -----------------
1572 dnl make ADAFLAGS consistent with CFLAGS
1573 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1574         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1575         case "$CFLAGS" in
1576         *-g*)
1577                 CF_ADD_ADAFLAGS(-g)
1578                 ;;
1579         esac
1580         case "$CFLAGS" in
1581         *-O*)
1582                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1583                 CF_ADD_ADAFLAGS($cf_O_flag)
1584                 ;;
1585         esac
1586         AC_MSG_RESULT($ADAFLAGS)
1587 ])dnl
1588 dnl ---------------------------------------------------------------------------
1589 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1590 dnl --------------
1591 dnl Forget that we saw the given tool.
1592 AC_DEFUN([CF_FORGET_TOOL],[
1593 unset ac_cv_prog_ac_ct_$1
1594 unset ac_ct_$1
1595 unset $1
1596 ])dnl
1597 dnl ---------------------------------------------------------------------------
1598 dnl CF_FUNC_DLSYM version: 3 updated: 2012/10/06 11:17:15
1599 dnl -------------
1600 dnl Test for dlsym() and related functions, as well as libdl.
1601 dnl
1602 dnl Sets
1603 dnl     $cf_have_dlsym
1604 dnl     $cf_have_libdl
1605 AC_DEFUN([CF_FUNC_DLSYM],[
1606 cf_have_dlsym=no
1607 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1608
1609 cf_have_libdl=no
1610 AC_CHECK_LIB(dl,dlsym,[
1611         cf_have_dlsym=yes
1612         cf_have_libdl=yes])])
1613
1614 if test "$cf_have_dlsym" = yes ; then
1615         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1616
1617         AC_MSG_CHECKING(whether able to link to dl*() functions)
1618         AC_TRY_LINK([#include <dlfcn.h>],[
1619                 void *obj;
1620                 if ((obj = dlopen("filename", 0)) != 0) {
1621                         if (dlsym(obj, "symbolname") == 0) {
1622                         dlclose(obj);
1623                         }
1624                 }],[
1625                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1626                 AC_MSG_ERROR(Cannot link test program for libdl)])
1627         AC_MSG_RESULT(ok)
1628 else
1629         AC_MSG_ERROR(Cannot find dlsym function)
1630 fi
1631 ])
1632 dnl ---------------------------------------------------------------------------
1633 dnl CF_FUNC_MEMMOVE version: 8 updated: 2012/10/04 20:12:20
1634 dnl ---------------
1635 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1636 dnl is found, add our own version of memmove to the list of objects.
1637 AC_DEFUN([CF_FUNC_MEMMOVE],
1638 [
1639 AC_CHECK_FUNC(memmove,,[
1640 AC_CHECK_FUNC(bcopy,[
1641         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1642                 AC_TRY_RUN([
1643 int main() {
1644         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1645         char temp[40];
1646         bcopy(data, temp, sizeof(data));
1647         bcopy(temp+10, temp, 15);
1648         bcopy(temp+5, temp+15, 10);
1649         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1650 }
1651                 ],
1652                 [cf_cv_good_bcopy=yes],
1653                 [cf_cv_good_bcopy=no],
1654                 [cf_cv_good_bcopy=unknown])
1655                 ])
1656         ],[cf_cv_good_bcopy=no])
1657         if test "$cf_cv_good_bcopy" = yes ; then
1658                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1659         else
1660                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1661         fi
1662 ])])dnl
1663 dnl ---------------------------------------------------------------------------
1664 dnl CF_FUNC_NANOSLEEP version: 4 updated: 2012/10/06 17:56:13
1665 dnl -----------------
1666 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1667 dnl AIX 4.x, provide a non-working version.
1668 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1669 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1670 AC_TRY_RUN([
1671 #include <stdio.h>
1672 #include <errno.h>
1673 #include <time.h>
1674
1675 #ifdef HAVE_SYS_TIME_H
1676 #include <sys/time.h>
1677 #endif
1678
1679 int main() {
1680         struct timespec ts1, ts2;
1681         int code;
1682         ts1.tv_sec  = 0;
1683         ts1.tv_nsec = 750000000;
1684         ts2.tv_sec  = 0;
1685         ts2.tv_nsec = 0;
1686         errno = 0;
1687         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1688         ${cf_cv_main_return:-return}(code != 0);
1689 }
1690 ],
1691         [cf_cv_func_nanosleep=yes],
1692         [cf_cv_func_nanosleep=no],
1693         [cf_cv_func_nanosleep=unknown])])
1694
1695 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1696 ])
1697 dnl ---------------------------------------------------------------------------
1698 dnl CF_FUNC_OPENPTY version: 3 updated: 2010/05/29 16:31:02
1699 dnl ---------------
1700 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1701 dnl "util" library as well.
1702 AC_DEFUN([CF_FUNC_OPENPTY],
1703 [
1704 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1705 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1706     cf_save_LIBS="$LIBS"
1707     test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1708     for cf_header in pty.h libutil.h util.h
1709     do
1710     AC_TRY_LINK([
1711 #include <$cf_header>
1712 ],[
1713     int x = openpty((int *)0, (int *)0, (char *)0,
1714                    (struct termios *)0, (struct winsize *)0);
1715 ],[
1716         cf_cv_func_openpty=$cf_header
1717         break
1718 ],[
1719         cf_cv_func_openpty=no
1720 ])
1721     done
1722     LIBS="$cf_save_LIBS"
1723 ])
1724 ])dnl
1725 dnl ---------------------------------------------------------------------------
1726 dnl CF_FUNC_POLL version: 8 updated: 2012/10/04 05:24:07
1727 dnl ------------
1728 dnl See if the poll function really works.  Some platforms have poll(), but
1729 dnl it does not work for terminals or files.
1730 AC_DEFUN([CF_FUNC_POLL],[
1731 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1732 AC_TRY_RUN([
1733 #include <stdlib.h>
1734 #include <stdio.h>
1735 #include <unistd.h>
1736 #include <fcntl.h>
1737 #ifdef HAVE_POLL_H
1738 #include <poll.h>
1739 #else
1740 #include <sys/poll.h>
1741 #endif
1742 int main() {
1743         struct pollfd myfds;
1744         int ret;
1745
1746         /* check for Darwin bug with respect to "devices" */
1747         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
1748         if (myfds.fd < 0)
1749                 myfds.fd = 0;
1750         myfds.events = POLLIN;
1751         myfds.revents = 0;
1752
1753         ret = poll(&myfds, 1, 100);
1754
1755         if (ret < 0 || (myfds.revents & POLLNVAL)) {
1756                 ret = -1;
1757         } else {
1758                 int fd = 0;
1759                 if (!isatty(fd)) {
1760                         fd = open("/dev/tty", 2);       /* O_RDWR */
1761                 }
1762
1763                 if (fd >= 0) {
1764                         /* also check with standard input */
1765                         myfds.fd = fd;
1766                         myfds.events = POLLIN;
1767                         myfds.revents = 0;
1768                         ret = poll(&myfds, 1, 100);
1769                 } else {
1770                         ret = -1;
1771                 }
1772         }
1773         ${cf_cv_main_return:-return}(ret < 0);
1774 }],
1775         [cf_cv_working_poll=yes],
1776         [cf_cv_working_poll=no],
1777         [cf_cv_working_poll=unknown])])
1778 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
1779 ])dnl
1780 dnl ---------------------------------------------------------------------------
1781 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
1782 dnl ---------------
1783 dnl Some old/broken variations define tcgetattr() only as a macro in
1784 dnl termio(s).h
1785 AC_DEFUN([CF_FUNC_TERMIOS],[
1786 AC_REQUIRE([CF_STRUCT_TERMIOS])
1787 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1788 AC_TRY_LINK([
1789 #include <sys/types.h>
1790 #ifdef HAVE_UNISTD_H
1791 #include <unistd.h>
1792 #endif
1793 #ifdef HAVE_TERMIOS_H
1794 #include <termios.h>
1795 #define TTY struct termios
1796 #else
1797 #ifdef HAVE_TERMIO_H
1798 #include <termio.h>
1799 #define TTY struct termio
1800 #endif
1801 #endif
1802 ],[
1803 TTY foo;
1804 tcgetattr(1, &foo);],
1805 [cf_cv_have_tcgetattr=yes],
1806 [cf_cv_have_tcgetattr=no])])
1807 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
1808 ])dnl
1809 dnl ---------------------------------------------------------------------------
1810 dnl CF_FUNC_VSSCANF version: 4 updated: 2012/10/06 17:56:13
1811 dnl ---------------
1812 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1813 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1814 dnl other functions.
1815 AC_DEFUN([CF_FUNC_VSSCANF],
1816 [
1817 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1818 AC_TRY_LINK([
1819 #include <stdarg.h>
1820 #include <stdio.h>],[
1821         va_list ap;
1822         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1823 AC_TRY_LINK([
1824 #include <stdarg.h>
1825 #include <stdio.h>],[
1826     FILE strbuf;
1827     char *str = "from";
1828
1829     strbuf._flag = _IOREAD;
1830     strbuf._ptr = strbuf._base = (unsigned char *) str;
1831     strbuf._cnt = strlen(str);
1832     strbuf._file = _NFILE;
1833     return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1834 AC_TRY_LINK([
1835 #include <stdarg.h>
1836 #include <stdio.h>],[
1837     FILE strbuf;
1838     char *str = "from";
1839
1840     strbuf._flag = _IOREAD;
1841     strbuf._ptr = strbuf._base = (unsigned char *) str;
1842     strbuf._cnt = strlen(str);
1843     strbuf._file = _NFILE;
1844     return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1845 cf_cv_func_vsscanf=no])])])])
1846
1847 case $cf_cv_func_vsscanf in #(vi
1848 vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);; #(vi
1849 vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);; #(vi
1850 _doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
1851 esac
1852
1853 ])dnl
1854 dnl ---------------------------------------------------------------------------
1855 dnl CF_GCC_ATTRIBUTES version: 16 updated: 2012/10/02 20:55:03
1856 dnl -----------------
1857 dnl Test for availability of useful gcc __attribute__ directives to quiet
1858 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1859 dnl to documentation, unrecognized directives cause older compilers to barf.
1860 AC_DEFUN([CF_GCC_ATTRIBUTES],
1861 [
1862 if test "$GCC" = yes
1863 then
1864 cat > conftest.i <<EOF
1865 #ifndef GCC_PRINTF
1866 #define GCC_PRINTF 0
1867 #endif
1868 #ifndef GCC_SCANF
1869 #define GCC_SCANF 0
1870 #endif
1871 #ifndef GCC_NORETURN
1872 #define GCC_NORETURN /* nothing */
1873 #endif
1874 #ifndef GCC_UNUSED
1875 #define GCC_UNUSED /* nothing */
1876 #endif
1877 EOF
1878 if test "$GCC" = yes
1879 then
1880         AC_CHECKING([for $CC __attribute__ directives])
1881 cat > conftest.$ac_ext <<EOF
1882 #line __oline__ "${as_me:-configure}"
1883 #include "confdefs.h"
1884 #include "conftest.h"
1885 #include "conftest.i"
1886 #if     GCC_PRINTF
1887 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1888 #else
1889 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1890 #endif
1891 #if     GCC_SCANF
1892 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1893 #else
1894 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1895 #endif
1896 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1897 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1898 extern void foo(void) GCC_NORETURN;
1899 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1900 EOF
1901         cf_printf_attribute=no
1902         cf_scanf_attribute=no
1903         for cf_attribute in scanf printf unused noreturn
1904         do
1905                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1906                 cf_directive="__attribute__(($cf_attribute))"
1907                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1908
1909                 case $cf_attribute in #(vi
1910                 printf) #(vi
1911                         cf_printf_attribute=yes
1912                         cat >conftest.h <<EOF
1913 #define GCC_$cf_ATTRIBUTE 1
1914 EOF
1915                         ;;
1916                 scanf) #(vi
1917                         cf_scanf_attribute=yes
1918                         cat >conftest.h <<EOF
1919 #define GCC_$cf_ATTRIBUTE 1
1920 EOF
1921                         ;;
1922                 *) #(vi
1923                         cat >conftest.h <<EOF
1924 #define GCC_$cf_ATTRIBUTE $cf_directive
1925 EOF
1926                         ;;
1927                 esac
1928
1929                 if AC_TRY_EVAL(ac_compile); then
1930                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1931                         cat conftest.h >>confdefs.h
1932                         case $cf_attribute in #(vi
1933                         noreturn) #(vi
1934                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1935                                 ;;
1936                         printf) #(vi
1937                                 cf_value='/* nothing */'
1938                                 if test "$cf_printf_attribute" != no ; then
1939                                         cf_value='__attribute__((format(printf,fmt,var)))'
1940                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1941                                 fi
1942                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1943                                 ;;
1944                         scanf) #(vi
1945                                 cf_value='/* nothing */'
1946                                 if test "$cf_scanf_attribute" != no ; then
1947                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1948                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1949                                 fi
1950                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1951                                 ;;
1952                         unused) #(vi
1953                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1954                                 ;;
1955                         esac
1956                 fi
1957         done
1958 else
1959         fgrep define conftest.i >>confdefs.h
1960 fi
1961 rm -rf conftest*
1962 fi
1963 ])dnl
1964 dnl ---------------------------------------------------------------------------
1965 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1966 dnl --------------
1967 dnl Find version of gcc
1968 AC_DEFUN([CF_GCC_VERSION],[
1969 AC_REQUIRE([AC_PROG_CC])
1970 GCC_VERSION=none
1971 if test "$GCC" = yes ; then
1972         AC_MSG_CHECKING(version of $CC)
1973         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1974         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1975         AC_MSG_RESULT($GCC_VERSION)
1976 fi
1977 ])dnl
1978 dnl ---------------------------------------------------------------------------
1979 dnl CF_GCC_WARNINGS version: 31 updated: 2013/11/19 19:23:35
1980 dnl ---------------
1981 dnl Check if the compiler supports useful warning options.  There's a few that
1982 dnl we don't use, simply because they're too noisy:
1983 dnl
1984 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1985 dnl     -Wredundant-decls (system headers make this too noisy)
1986 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1987 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1988 dnl             is enabled for ncurses using "--enable-const".
1989 dnl     -pedantic
1990 dnl
1991 dnl Parameter:
1992 dnl     $1 is an optional list of gcc warning flags that a particular
1993 dnl             application might want to use, e.g., "no-unused" for
1994 dnl             -Wno-unused
1995 dnl Special:
1996 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1997 dnl
1998 AC_DEFUN([CF_GCC_WARNINGS],
1999 [
2000 AC_REQUIRE([CF_GCC_VERSION])
2001 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2002 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2003
2004 cat > conftest.$ac_ext <<EOF
2005 #line __oline__ "${as_me:-configure}"
2006 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2007 EOF
2008
2009 if test "$INTEL_COMPILER" = yes
2010 then
2011 # The "-wdXXX" options suppress warnings:
2012 # remark #1419: external declaration in primary source file
2013 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2014 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2015 # remark #193: zero used for undefined preprocessing identifier
2016 # remark #593: variable "curs_sb_left_arrow" was set but never used
2017 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2018 # remark #869: parameter "tw" was never referenced
2019 # remark #981: operands are evaluated in unspecified order
2020 # warning #279: controlling expression is constant
2021
2022         AC_CHECKING([for $CC warning options])
2023         cf_save_CFLAGS="$CFLAGS"
2024         EXTRA_CFLAGS="-Wall"
2025         for cf_opt in \
2026                 wd1419 \
2027                 wd1683 \
2028                 wd1684 \
2029                 wd193 \
2030                 wd593 \
2031                 wd279 \
2032                 wd810 \
2033                 wd869 \
2034                 wd981
2035         do
2036                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2037                 if AC_TRY_EVAL(ac_compile); then
2038                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2039                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2040                 fi
2041         done
2042         CFLAGS="$cf_save_CFLAGS"
2043
2044 elif test "$GCC" = yes
2045 then
2046         AC_CHECKING([for $CC warning options])
2047         cf_save_CFLAGS="$CFLAGS"
2048         EXTRA_CFLAGS=
2049         cf_warn_CONST=""
2050         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2051         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2052         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2053         for cf_opt in W Wall \
2054                 Wbad-function-cast \
2055                 Wcast-align \
2056                 Wcast-qual \
2057                 Wdeclaration-after-statement \
2058                 Wextra \
2059                 Winline \
2060                 Wmissing-declarations \
2061                 Wmissing-prototypes \
2062                 Wnested-externs \
2063                 Wpointer-arith \
2064                 Wshadow \
2065                 Wstrict-prototypes \
2066                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2067         do
2068                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2069                 if AC_TRY_EVAL(ac_compile); then
2070                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2071                         case $cf_opt in #(vi
2072                         Wcast-qual) #(vi
2073                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2074                                 ;;
2075                         Winline) #(vi
2076                                 case $GCC_VERSION in
2077                                 [[34]].*)
2078                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2079                                         continue;;
2080                                 esac
2081                                 ;;
2082                         Wpointer-arith) #(vi
2083                                 case $GCC_VERSION in
2084                                 [[12]].*)
2085                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2086                                         continue;;
2087                                 esac
2088                                 ;;
2089                         esac
2090                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2091                 fi
2092         done
2093         CFLAGS="$cf_save_CFLAGS"
2094 fi
2095 rm -rf conftest*
2096
2097 AC_SUBST(EXTRA_CFLAGS)
2098 ])dnl
2099 dnl ---------------------------------------------------------------------------
2100 dnl CF_GETOPT_HEADER version: 5 updated: 2012/10/06 16:39:58
2101 dnl ----------------
2102 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2103 dnl unistd.h or (nonstandard) in getopt.h
2104 AC_DEFUN([CF_GETOPT_HEADER],
2105 [
2106 AC_HAVE_HEADERS(unistd.h getopt.h)
2107 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2108 cf_cv_getopt_header=none
2109 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2110 do
2111 AC_TRY_COMPILE([
2112 #include <$cf_header>],
2113 [int x = optind; char *y = optarg],
2114 [cf_cv_getopt_header=$cf_header
2115  break])
2116 done
2117 ])
2118 if test $cf_cv_getopt_header != none ; then
2119         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if we need to include getopt.h])
2120 fi
2121 ])dnl
2122 dnl ---------------------------------------------------------------------------
2123 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
2124 dnl ----------------
2125 AC_DEFUN([CF_GNAT_GENERICS],
2126 [
2127 AC_REQUIRE([CF_GNAT_VERSION])
2128
2129 AC_MSG_CHECKING(if GNAT supports generics)
2130 case $cf_gnat_version in #(vi
2131 3.[[1-9]]*|[[4-9]].*) #(vi
2132         cf_gnat_generics=yes
2133         ;;
2134 *)
2135         cf_gnat_generics=no
2136         ;;
2137 esac
2138 AC_MSG_RESULT($cf_gnat_generics)
2139
2140 if test "$cf_gnat_generics" = yes
2141 then
2142         cf_compile_generics=generics
2143         cf_generic_objects="\${GENOBJS}"
2144 else
2145         cf_compile_generics=
2146         cf_generic_objects=
2147 fi
2148
2149 AC_SUBST(cf_compile_generics)
2150 AC_SUBST(cf_generic_objects)
2151 ])dnl
2152 dnl ---------------------------------------------------------------------------
2153 dnl CF_GNAT_PROJECTS version: 5 updated: 2014/05/24 13:30:20
2154 dnl ----------------
2155 dnl GNAT projects are configured with ".gpr" project files.
2156 dnl GNAT libraries are a further development, using the project feature.
2157 AC_DEFUN([CF_GNAT_PROJECTS],
2158 [
2159 AC_REQUIRE([CF_GNAT_VERSION])
2160
2161 cf_gnat_projects=no
2162
2163 AC_MSG_CHECKING(if GNAT supports project files)
2164 case $cf_gnat_version in #(vi
2165 3.[[0-9]]*) #(vi
2166         ;;
2167 *)
2168         case $cf_cv_system_name in #(vi
2169         cygwin*|msys*) #(vi
2170                 ;;
2171         *)
2172                 mkdir conftest
2173                 cd conftest
2174                 mkdir lib obj
2175                 cat >>library.gpr <<CF_EOF
2176 project Library is
2177   for Library_Name use "ConfTest";
2178   for Object_Dir use "obj";
2179   for Library_Version use "libConfTest.so.1";
2180   for Library_Kind use "dynamic";
2181   for Library_Dir use "lib";
2182   for Source_Dirs use (".");
2183 end Library;
2184 CF_EOF
2185                 cat >>confpackage.ads <<CF_EOF
2186 package ConfPackage is
2187    procedure conftest;
2188 end ConfPackage;
2189 CF_EOF
2190                 cat >>confpackage.adb <<CF_EOF
2191 with Text_IO;
2192 package body ConfPackage is
2193    procedure conftest is
2194    begin
2195       Text_IO.Put ("Hello World");
2196       Text_IO.New_Line;
2197    end conftest;
2198 end ConfPackage;
2199 CF_EOF
2200                 if ( $cf_ada_make -Plibrary.gpr 1>&AC_FD_CC 2>&1 ); then
2201                         cf_gnat_projects=yes
2202                 fi
2203                 cd ..
2204                 rm -rf conftest
2205                 ;;
2206         esac
2207         ;;
2208 esac
2209 AC_MSG_RESULT($cf_gnat_projects)
2210 ])dnl
2211 dnl ---------------------------------------------------------------------------
2212 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2213 dnl --------------
2214 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2215 dnl is noted that gnat may compile a tasking unit even for configurations which
2216 dnl fail at runtime.
2217 AC_DEFUN([CF_GNAT_SIGINT],[
2218 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2219 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2220
2221 package ConfTest is
2222
2223    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2224    pragma Unreserve_All_Interrupts;
2225    pragma Warnings (On);
2226
2227    protected Process is
2228       procedure Stop;
2229       function Continue return Boolean;
2230       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2231    private
2232       Done : Boolean := False;
2233    end Process;
2234
2235 end ConfTest;],
2236 [package body ConfTest is
2237    protected body Process is
2238       procedure Stop is
2239       begin
2240          Done := True;
2241       end Stop;
2242       function Continue return Boolean is
2243       begin
2244          return not Done;
2245       end Continue;
2246    end Process;
2247 end ConfTest;],
2248         [cf_cv_gnat_sigint=yes],
2249         [cf_cv_gnat_sigint=no])])
2250
2251 if test $cf_cv_gnat_sigint = yes ; then
2252         USE_GNAT_SIGINT=""
2253 else
2254         USE_GNAT_SIGINT="#"
2255 fi
2256 AC_SUBST(USE_GNAT_SIGINT)
2257 ])dnl
2258 dnl ---------------------------------------------------------------------------
2259 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2260 dnl ----------------
2261 dnl Verify that a test program compiles/links with GNAT.
2262 dnl $cf_ada_make is set to the program that compiles/links
2263 dnl $ADAFLAGS may be set to the GNAT flags.
2264 dnl
2265 dnl $1 is the text of the spec
2266 dnl $2 is the text of the body
2267 dnl $3 is the shell command to execute if successful
2268 dnl $4 is the shell command to execute if not successful
2269 AC_DEFUN([CF_GNAT_TRY_LINK],
2270 [
2271 rm -rf conftest* *~conftest*
2272 cat >>conftest.ads <<CF_EOF
2273 $1
2274 CF_EOF
2275 cat >>conftest.adb <<CF_EOF
2276 $2
2277 CF_EOF
2278 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2279 ifelse($3,,      :,[      $3])
2280 ifelse($4,,,[else
2281    $4])
2282 fi
2283 rm -rf conftest* *~conftest*
2284 ])dnl
2285 dnl ---------------------------------------------------------------------------
2286 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2287 dnl ---------------
2288 dnl Verify that a test program compiles and runs with GNAT
2289 dnl $cf_ada_make is set to the program that compiles/links
2290 dnl $ADAFLAGS may be set to the GNAT flags.
2291 dnl
2292 dnl $1 is the text of the spec
2293 dnl $2 is the text of the body
2294 dnl $3 is the shell command to execute if successful
2295 dnl $4 is the shell command to execute if not successful
2296 AC_DEFUN([CF_GNAT_TRY_RUN],
2297 [
2298 rm -rf conftest* *~conftest*
2299 cat >>conftest.ads <<CF_EOF
2300 $1
2301 CF_EOF
2302 cat >>conftest.adb <<CF_EOF
2303 $2
2304 CF_EOF
2305 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2306    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2307 ifelse($3,,      :,[      $3])
2308 ifelse($4,,,[   else
2309       $4])
2310    fi
2311 ifelse($4,,,[else
2312    $4])
2313 fi
2314 rm -rf conftest* *~conftest*
2315 ])dnl
2316 dnl ---------------------------------------------------------------------------
2317 dnl CF_GNAT_VERSION version: 18 updated: 2012/01/21 19:28:10
2318 dnl ---------------
2319 dnl Verify version of GNAT.
2320 AC_DEFUN([CF_GNAT_VERSION],
2321 [
2322 AC_MSG_CHECKING(for gnat version)
2323 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2324         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2325     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2326 AC_MSG_RESULT($cf_gnat_version)
2327
2328 case $cf_gnat_version in #(vi
2329 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]]) #(vi
2330         cf_cv_prog_gnat_correct=yes
2331         ;;
2332 *)
2333         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2334         cf_cv_prog_gnat_correct=no
2335         ;;
2336 esac
2337 ])
2338 dnl ---------------------------------------------------------------------------
2339 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2340 dnl -------------
2341 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2342 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2343 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2344 dnl since it is interwoven with GNU extensions.
2345 dnl
2346 dnl Well, yes we could work around it...
2347 AC_DEFUN([CF_GNU_SOURCE],
2348 [
2349 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2350 AC_TRY_COMPILE([#include <sys/types.h>],[
2351 #ifndef _XOPEN_SOURCE
2352 make an error
2353 #endif],
2354         [cf_cv_gnu_source=no],
2355         [cf_save="$CPPFLAGS"
2356          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2357          AC_TRY_COMPILE([#include <sys/types.h>],[
2358 #ifdef _XOPEN_SOURCE
2359 make an error
2360 #endif],
2361         [cf_cv_gnu_source=no],
2362         [cf_cv_gnu_source=yes])
2363         CPPFLAGS="$cf_save"
2364         ])
2365 ])
2366 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2367 ])dnl
2368 dnl ---------------------------------------------------------------------------
2369 dnl CF_GPP_LIBRARY version: 11 updated: 2012/10/06 17:56:13
2370 dnl --------------
2371 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2372 dnl problem :-).  If we have the compiler but no library, we'll be able to
2373 dnl configure, but won't be able to build the c++ demo program.
2374 AC_DEFUN([CF_GPP_LIBRARY],
2375 [
2376 cf_cxx_library=unknown
2377 case $cf_cv_system_name in #(vi
2378 os2*) #(vi
2379         cf_gpp_libname=gpp
2380         ;;
2381 *)
2382         cf_gpp_libname=g++
2383         ;;
2384 esac
2385 if test "$GXX" = yes; then
2386         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2387         cf_save="$LIBS"
2388         CF_ADD_LIB($cf_gpp_libname)
2389         AC_TRY_LINK([
2390 #include <$cf_gpp_libname/builtin.h>
2391         ],
2392         [two_arg_error_handler_t foo2 = lib_error_handler],
2393         [cf_cxx_library=yes
2394          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2395          if test "$cf_gpp_libname" = cpp ; then
2396             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2397          else
2398             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2399          fi],
2400         [AC_TRY_LINK([
2401 #include <builtin.h>
2402         ],
2403         [two_arg_error_handler_t foo2 = lib_error_handler],
2404         [cf_cxx_library=yes
2405          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2406          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2407         [cf_cxx_library=no])])
2408         LIBS="$cf_save"
2409         AC_MSG_RESULT($cf_cxx_library)
2410 fi
2411 ])dnl
2412 dnl ---------------------------------------------------------------------------
2413 dnl CF_GXX_VERSION version: 7 updated: 2012/06/16 14:55:39
2414 dnl --------------
2415 dnl Check for version of g++
2416 AC_DEFUN([CF_GXX_VERSION],[
2417 AC_REQUIRE([AC_PROG_CPP])
2418 GXX_VERSION=none
2419 if test "$GXX" = yes; then
2420         AC_MSG_CHECKING(version of ${CXX:-g++})
2421         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2422         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2423         AC_MSG_RESULT($GXX_VERSION)
2424 fi
2425 ])dnl
2426 dnl ---------------------------------------------------------------------------
2427 dnl CF_GXX_WARNINGS version: 8 updated: 2013/11/16 14:27:53
2428 dnl ---------------
2429 dnl Check if the compiler supports useful warning options.
2430 dnl
2431 dnl Most of gcc's options apply to g++, except:
2432 dnl     -Wbad-function-cast
2433 dnl     -Wmissing-declarations
2434 dnl     -Wnested-externs
2435 dnl
2436 dnl Omit a few (for now):
2437 dnl     -Winline
2438 dnl
2439 dnl Parameter:
2440 dnl     $1 is an optional list of g++ warning flags that a particular
2441 dnl             application might want to use, e.g., "no-unused" for
2442 dnl             -Wno-unused
2443 dnl Special:
2444 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2445 dnl
2446 AC_DEFUN([CF_GXX_WARNINGS],
2447 [
2448
2449 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2450 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2451
2452 AC_REQUIRE([CF_GXX_VERSION])
2453
2454 AC_LANG_SAVE
2455 AC_LANG_CPLUSPLUS
2456
2457 cat > conftest.$ac_ext <<EOF
2458 #line __oline__ "configure"
2459 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2460 EOF
2461
2462 if test "$INTEL_CPLUSPLUS" = yes
2463 then
2464 # The "-wdXXX" options suppress warnings:
2465 # remark #1419: external declaration in primary source file
2466 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2467 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2468 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2469 # remark #193: zero used for undefined preprocessing identifier
2470 # remark #593: variable "curs_sb_left_arrow" was set but never used
2471 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2472 # remark #869: parameter "tw" was never referenced
2473 # remark #981: operands are evaluated in unspecified order
2474 # warning #269: invalid format string conversion
2475
2476         AC_CHECKING([for $CC warning options])
2477         cf_save_CXXFLAGS="$CXXFLAGS"
2478         EXTRA_CXXFLAGS="-Wall"
2479         for cf_opt in \
2480                 wd1419 \
2481                 wd1682 \
2482                 wd1683 \
2483                 wd1684 \
2484                 wd193 \
2485                 wd279 \
2486                 wd593 \
2487                 wd810 \
2488                 wd869 \
2489                 wd981
2490         do
2491                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2492                 if AC_TRY_EVAL(ac_compile); then
2493                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2494                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2495                 fi
2496         done
2497         CXXFLAGS="$cf_save_CXXFLAGS"
2498
2499 elif test "$GXX" = yes
2500 then
2501         AC_CHECKING([for $CXX warning options])
2502         cf_save_CXXFLAGS="$CXXFLAGS"
2503         EXTRA_CXXFLAGS="-W -Wall"
2504         cf_gxx_extra_warnings=""
2505         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2506         case "$GCC_VERSION" in
2507         [[1-2]].*)
2508                 ;;
2509         *)
2510                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2511                 ;;
2512         esac
2513         for cf_opt in \
2514                 Wabi \
2515                 fabi-version=0 \
2516                 Wextra \
2517                 Wignored-qualifiers \
2518                 Wlogical-op \
2519                 Woverloaded-virtual \
2520                 Wsign-promo \
2521                 Wsynth \
2522                 Wold-style-cast \
2523                 Wcast-align \
2524                 Wcast-qual \
2525                 Wpointer-arith \
2526                 Wshadow \
2527                 Wundef $cf_gxx_extra_warnings $1
2528         do
2529                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2530                 if AC_TRY_EVAL(ac_compile); then
2531                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2532                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2533                 else
2534                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2535                 fi
2536         done
2537         CXXFLAGS="$cf_save_CXXFLAGS"
2538 fi
2539
2540 rm -rf conftest*
2541 AC_LANG_RESTORE
2542 AC_SUBST(EXTRA_CXXFLAGS)
2543 ])dnl
2544 dnl ---------------------------------------------------------------------------
2545 dnl CF_HASHED_DB version: 5 updated: 2014/04/12 16:47:01
2546 dnl ------------
2547 dnl Look for an instance of the Berkeley hashed database.
2548 dnl
2549 dnl $1 = optional parameter, to specify install-prefix for the database.
2550 AC_DEFUN([CF_HASHED_DB],
2551 [
2552 ifelse([$1],,,[
2553 case $1 in #(vi
2554 yes|*able*) #(vi
2555     ;;
2556 *)
2557     if test -d "$1" ; then
2558         CF_ADD_INCDIR($1/include)
2559         CF_ADD_LIBDIR($1/lib)
2560         else
2561                 case "$1" in #(vi
2562                 ./*|../*|/*)
2563                         AC_MSG_WARN(no such directory $1)
2564                         ;; #(vi
2565                 *)
2566                         CF_FIND_SUB_INCDIR($1)
2567                         CF_FIND_SUB_LIBDIR($1)
2568                         ;;
2569                 esac
2570     fi
2571 esac
2572 ])
2573 AC_CHECK_HEADER(db.h,[
2574 CF_HASHED_DB_VERSION
2575 if test "$cf_cv_hashed_db_version" = unknown ; then
2576         AC_MSG_ERROR(Cannot determine version of db)
2577 else
2578         CF_HASHED_DB_LIBS
2579         if test "$cf_cv_hashed_db_libs" = unknown ; then
2580                 AC_MSG_ERROR(Cannot determine library for db)
2581         elif test "$cf_cv_hashed_db_libs" != default ; then
2582                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2583         fi
2584 fi
2585 ],[
2586         AC_MSG_ERROR(Cannot find db.h)
2587 ])
2588 ])dnl
2589 dnl ---------------------------------------------------------------------------
2590 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2591 dnl -----------------
2592 dnl Given that we have the header and version for hashed database, find the
2593 dnl library information.
2594 AC_DEFUN([CF_HASHED_DB_LIBS],
2595 [
2596 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2597 cf_cv_hashed_db_libs=unknown
2598 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2599 do
2600         cf_save_libs="$LIBS"
2601         if test -n "$cf_db_libs"; then
2602                 CF_ADD_LIB($cf_db_libs)
2603         fi
2604         CF_MSG_LOG(checking for library "$cf_db_libs")
2605         AC_TRY_LINK([
2606 $ac_includes_default
2607 #include <db.h>
2608 ],[
2609         char *path = "/tmp/foo";
2610 #ifdef DB_VERSION_MAJOR
2611 #if DB_VERSION_MAJOR >= 4
2612         DB *result = 0;
2613         db_create(&result, NULL, 0);
2614         result->open(result,
2615                 NULL,
2616                 path,
2617                 path,
2618                 DB_HASH,
2619                 DB_CREATE,
2620                 0644);
2621 #elif DB_VERSION_MAJOR >= 3
2622         DB *result = 0;
2623         db_create(&result, NULL, 0);
2624         result->open(result,
2625                 path,
2626                 path,
2627                 DB_HASH,
2628                 DB_CREATE,
2629                 0644);
2630 #elif DB_VERSION_MAJOR >= 2
2631         DB *result = 0;
2632         db_open(path,
2633                 DB_HASH,
2634                 DB_CREATE,
2635                 0644,
2636                 (DB_ENV *) 0,
2637                 (DB_INFO *) 0,
2638                 &result);
2639 #endif /* DB_VERSION_MAJOR */
2640 #else
2641         DB *result = dbopen(path,
2642                      2,
2643                      0644,
2644                      DB_HASH,
2645                      0);
2646 #endif
2647         ${cf_cv_main_return:-return}(result != 0)
2648 ],[
2649         if test -n "$cf_db_libs" ; then
2650                 cf_cv_hashed_db_libs=$cf_db_libs
2651         else
2652                 cf_cv_hashed_db_libs=default
2653         fi
2654         LIBS="$cf_save_libs"
2655         break
2656 ])
2657         LIBS="$cf_save_libs"
2658 done
2659 ])
2660 ])dnl
2661 dnl ---------------------------------------------------------------------------
2662 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
2663 dnl --------------------
2664 dnl Given that we have the header file for hashed database, find the version
2665 dnl information.
2666 AC_DEFUN([CF_HASHED_DB_VERSION],
2667 [
2668 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2669 cf_cv_hashed_db_version=unknown
2670
2671 for cf_db_version in 1 2 3 4 5 6
2672 do
2673         CF_MSG_LOG(checking for db version $cf_db_version)
2674         AC_TRY_COMPILE([
2675 $ac_includes_default
2676 #include <db.h>
2677
2678 #ifdef DB_VERSION_MAJOR
2679         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2680 #if $cf_db_version == DB_VERSION_MAJOR
2681         /* ok */
2682 #else
2683         make an error
2684 #endif
2685 #else
2686 #if $cf_db_version == 1
2687         /* ok: assuming this is DB 1.8.5 */
2688 #else
2689         make an error
2690 #endif
2691 #endif
2692 ],[DBT *foo = 0],[
2693         cf_cv_hashed_db_version=$cf_db_version
2694         break
2695         ])
2696 done
2697 ])
2698 ])dnl
2699 dnl ---------------------------------------------------------------------------
2700 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
2701 dnl --------------
2702 dnl Construct a search-list of directories for a nonstandard header-file
2703 dnl
2704 dnl Parameters
2705 dnl     $1 = the variable to return as result
2706 dnl     $2 = the package name
2707 AC_DEFUN([CF_HEADER_PATH],
2708 [
2709 $1=
2710
2711 # collect the current set of include-directories from compiler flags
2712 cf_header_path_list=""
2713 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2714         for cf_header_path in $CPPFLAGS $CFLAGS
2715         do
2716                 case $cf_header_path in #(vi
2717                 -I*)
2718                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2719                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2720                         cf_header_path_list="$cf_header_path_list [$]$1"
2721                         ;;
2722                 esac
2723         done
2724 fi
2725
2726 # add the variations for the package we are looking for
2727 CF_SUBDIR_PATH($1,$2,include)
2728
2729 test "$includedir" != NONE && \
2730 test "$includedir" != "/usr/include" && \
2731 test -d "$includedir" && {
2732         test -d $includedir &&    $1="[$]$1 $includedir"
2733         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2734 }
2735
2736 test "$oldincludedir" != NONE && \
2737 test "$oldincludedir" != "/usr/include" && \
2738 test -d "$oldincludedir" && {
2739         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2740         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2741 }
2742
2743 $1="[$]$1 $cf_header_path_list"
2744 ])dnl
2745 dnl ---------------------------------------------------------------------------
2746 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2747 dnl ---------------
2748 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2749 AC_DEFUN([CF_HELP_MESSAGE],
2750 [AC_DIVERT_HELP([$1])dnl
2751 ])dnl
2752 dnl ---------------------------------------------------------------------------
2753 dnl CF_INCLUDE_DIRS version: 8 updated: 2013/10/12 16:45:09
2754 dnl ---------------
2755 dnl Construct the list of include-options according to whether we're building
2756 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
2757 dnl with gcc, don't append the includedir if it happens to be /usr/include,
2758 dnl since that usually breaks gcc's shadow-includes.
2759 AC_DEFUN([CF_INCLUDE_DIRS],
2760 [
2761 if test "$GCC" != yes; then
2762         CPPFLAGS="-I\${includedir} $CPPFLAGS"
2763 elif test "$includedir" != "/usr/include"; then
2764         if test "$includedir" = '${prefix}/include' ; then
2765                 if test x$prefix != x/usr ; then
2766                         CPPFLAGS="-I\${includedir} $CPPFLAGS"
2767                 fi
2768         else
2769                 CPPFLAGS="-I\${includedir} $CPPFLAGS"
2770         fi
2771 fi
2772 if test "$srcdir" != "."; then
2773         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
2774 fi
2775 CPPFLAGS="-I. -I../include $CPPFLAGS"
2776 AC_SUBST(CPPFLAGS)
2777 ])dnl
2778 dnl ---------------------------------------------------------------------------
2779 dnl CF_INTEL_COMPILER version: 6 updated: 2014/03/17 13:13:07
2780 dnl -----------------
2781 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2782 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2783 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2784 dnl
2785 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2786 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2787 dnl the wrappers for gcc and g++ warnings.
2788 dnl
2789 dnl $1 = GCC (default) or GXX
2790 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2791 dnl $3 = CFLAGS (default) or CXXFLAGS
2792 AC_DEFUN([CF_INTEL_COMPILER],[
2793 AC_REQUIRE([AC_CANONICAL_HOST])
2794 ifelse([$2],,INTEL_COMPILER,[$2])=no
2795
2796 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2797         case $host_os in
2798         linux*|gnu*)
2799                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2800                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2801                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2802                 AC_TRY_COMPILE([],[
2803 #ifdef __INTEL_COMPILER
2804 #else
2805 make an error
2806 #endif
2807 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2808 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
2809 ],[])
2810                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2811                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2812                 ;;
2813         esac
2814 fi
2815 ])dnl
2816 dnl ---------------------------------------------------------------------------
2817 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
2818 dnl ----------
2819 dnl Check if we have either a function or macro for 'isascii()'.
2820 AC_DEFUN([CF_ISASCII],
2821 [
2822 AC_MSG_CHECKING(for isascii)
2823 AC_CACHE_VAL(cf_cv_have_isascii,[
2824         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2825         [cf_cv_have_isascii=yes],
2826         [cf_cv_have_isascii=no])
2827 ])dnl
2828 AC_MSG_RESULT($cf_cv_have_isascii)
2829 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
2830 ])dnl
2831 dnl ---------------------------------------------------------------------------
2832 dnl CF_LARGEFILE version: 8 updated: 2012/10/06 08:57:51
2833 dnl ------------
2834 dnl Add checks for large file support.
2835 AC_DEFUN([CF_LARGEFILE],[
2836 ifdef([AC_FUNC_FSEEKO],[
2837     AC_SYS_LARGEFILE
2838     if test "$enable_largefile" != no ; then
2839         AC_FUNC_FSEEKO
2840
2841         # Normally we would collect these definitions in the config.h,
2842         # but (like _XOPEN_SOURCE), some environments rely on having these
2843         # defined before any of the system headers are included.  Another
2844         # case comes up with C++, e.g., on AIX the compiler compiles the
2845         # header files by themselves before looking at the body files it is
2846         # told to compile.  For ncurses, those header files do not include
2847         # the config.h
2848         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2849         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2850         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2851
2852         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2853                 AC_TRY_COMPILE([
2854 #include <sys/types.h>
2855 #include <dirent.h>
2856                 ],[
2857                 /* if transitional largefile support is setup, this is true */
2858                 extern struct dirent64 * readdir(DIR *);
2859                 struct dirent64 *x = readdir((DIR *)0);
2860                 struct dirent *y = readdir((DIR *)0);
2861                 int z = x - y;
2862                 ],
2863                 [cf_cv_struct_dirent64=yes],
2864                 [cf_cv_struct_dirent64=no])
2865         ])
2866         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
2867     fi
2868 ])
2869 ])
2870 dnl ---------------------------------------------------------------------------
2871 dnl CF_LDFLAGS_STATIC version: 10 updated: 2011/09/24 12:51:48
2872 dnl -----------------
2873 dnl Check for compiler/linker flags used to temporarily force usage of static
2874 dnl libraries.  This depends on the compiler and platform.  Use this to help
2875 dnl ensure that the linker picks up a given library based on its position in
2876 dnl the list of linker options and libraries.
2877 AC_DEFUN([CF_LDFLAGS_STATIC],[
2878
2879 if test "$GCC" = yes ; then
2880         case $cf_cv_system_name in #(
2881         OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)         #( vi
2882                 LDFLAGS_STATIC=
2883                 LDFLAGS_SHARED=
2884                 ;;
2885     *)  #( normally, except when broken
2886         LDFLAGS_STATIC=-static
2887         LDFLAGS_SHARED=-dynamic
2888         ;;
2889     esac
2890 else
2891         case $cf_cv_system_name in #(
2892         aix[[4-7]]*)    #( from ld manpage
2893                 LDFLAGS_STATIC=-bstatic
2894                 LDFLAGS_SHARED=-bdynamic
2895                 ;;
2896         hpux*)          #( from ld manpage for hpux10.20, hpux11.11
2897                 # We could also use just "archive" and "shared".
2898                 LDFLAGS_STATIC=-Wl,-a,archive_shared
2899                 LDFLAGS_SHARED=-Wl,-a,shared_archive
2900                 ;;
2901         irix*)          #( from ld manpage IRIX64
2902                 LDFLAGS_STATIC=-Bstatic
2903                 LDFLAGS_SHARED=-Bdynamic
2904                 ;;
2905         osf[[45]]*)     #( from ld manpage osf4.0d, osf5.1
2906                 # alternative "-oldstyle_liblookup" (not in cc manpage)
2907                 LDFLAGS_STATIC=-noso
2908                 LDFLAGS_SHARED=-so_archive
2909                 ;;
2910         solaris2*)
2911                 LDFLAGS_STATIC=-Bstatic
2912                 LDFLAGS_SHARED=-Bdynamic
2913                 ;;
2914         esac
2915 fi
2916
2917 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
2918 then
2919         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
2920
2921         rm -f libconftest.a
2922         cat >conftest.$ac_ext <<EOF
2923 #line __oline__ "configure"
2924 #include <stdio.h>
2925 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
2926 EOF
2927         if AC_TRY_EVAL(ac_compile) ; then
2928                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
2929                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
2930         fi
2931         rm -f conftest.*
2932
2933         cf_save_LIBS="$LIBS"
2934
2935         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
2936         AC_TRY_LINK([
2937 #line __oline__ "configure"
2938 #include <stdio.h>
2939 int cf_ldflags_static(FILE *fp);
2940 ],[
2941         return cf_ldflags_static(stdin);
2942 ],[
2943         # some linkers simply ignore the -dynamic
2944         case x`file conftest$ac_exeext 2>/dev/null` in #(vi
2945         *static*) # (vi
2946                 cf_ldflags_static=no
2947                 ;;
2948         *)
2949                 cf_ldflags_static=yes
2950                 ;;
2951         esac
2952 ],[cf_ldflags_static=no])
2953
2954         rm -f libconftest.*
2955         LIBS="$cf_save_LIBS"
2956
2957         AC_MSG_RESULT($cf_ldflags_static)
2958
2959         if test $cf_ldflags_static != yes
2960         then
2961                 LDFLAGS_STATIC=
2962                 LDFLAGS_SHARED=
2963         fi
2964 else
2965         LDFLAGS_STATIC=
2966         LDFLAGS_SHARED=
2967 fi
2968
2969 AC_SUBST(LDFLAGS_STATIC)
2970 AC_SUBST(LDFLAGS_SHARED)
2971 ])
2972 dnl ---------------------------------------------------------------------------
2973 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
2974 dnl ---------------
2975 dnl For the given system and compiler, find the compiler flags to pass to the
2976 dnl loader to use the "rpath" feature.
2977 AC_DEFUN([CF_LD_RPATH_OPT],
2978 [
2979 AC_REQUIRE([CF_CHECK_CACHE])
2980
2981 LD_RPATH_OPT=
2982 AC_MSG_CHECKING(for an rpath option)
2983 case $cf_cv_system_name in #(vi
2984 irix*) #(vi
2985         if test "$GCC" = yes; then
2986                 LD_RPATH_OPT="-Wl,-rpath,"
2987         else
2988                 LD_RPATH_OPT="-rpath "
2989         fi
2990         ;;
2991 linux*|gnu*|k*bsd*-gnu) #(vi
2992         LD_RPATH_OPT="-Wl,-rpath,"
2993         ;;
2994 openbsd[[2-9]].*|mirbsd*) #(vi
2995         LD_RPATH_OPT="-Wl,-rpath,"
2996         ;;
2997 dragonfly*|freebsd*) #(vi
2998         LD_RPATH_OPT="-rpath "
2999         ;;
3000 netbsd*) #(vi
3001         LD_RPATH_OPT="-Wl,-rpath,"
3002         ;;
3003 osf*|mls+*) #(vi
3004         LD_RPATH_OPT="-rpath "
3005         ;;
3006 solaris2*) #(vi
3007         LD_RPATH_OPT="-R"
3008         ;;
3009 *)
3010         ;;
3011 esac
3012 AC_MSG_RESULT($LD_RPATH_OPT)
3013
3014 case "x$LD_RPATH_OPT" in #(vi
3015 x-R*)
3016         AC_MSG_CHECKING(if we need a space after rpath option)
3017         cf_save_LIBS="$LIBS"
3018         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3019         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3020         LIBS="$cf_save_LIBS"
3021         AC_MSG_RESULT($cf_rpath_space)
3022         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3023         ;;
3024 esac
3025 ])dnl
3026 dnl ---------------------------------------------------------------------------
3027 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
3028 dnl ---------------
3029 dnl Construct a search-list of directories for a nonstandard library-file
3030 dnl
3031 dnl Parameters
3032 dnl     $1 = the variable to return as result
3033 dnl     $2 = the package name
3034 AC_DEFUN([CF_LIBRARY_PATH],
3035 [
3036 $1=
3037 cf_library_path_list=""
3038 if test -n "${LDFLAGS}${LIBS}" ; then
3039         for cf_library_path in $LDFLAGS $LIBS
3040         do
3041                 case $cf_library_path in #(vi
3042                 -L*)
3043                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3044                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3045                         cf_library_path_list="$cf_library_path_list [$]$1"
3046                         ;;
3047                 esac
3048         done
3049 fi
3050
3051 CF_SUBDIR_PATH($1,$2,lib)
3052
3053 $1="$cf_library_path_list [$]$1"
3054 ])dnl
3055 dnl ---------------------------------------------------------------------------
3056 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3057 dnl ------------------
3058 AC_DEFUN([CF_LIBTOOL_VERSION],[
3059 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3060 then
3061         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3062 else
3063         cf_cv_libtool_version=
3064 fi
3065 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3066 ])dnl
3067 dnl ---------------------------------------------------------------------------
3068 dnl CF_LIB_PREFIX version: 9 updated: 2012/01/21 19:28:10
3069 dnl -------------
3070 dnl Compute the library-prefix for the given host system
3071 dnl $1 = variable to set
3072 define([CF_LIB_PREFIX],
3073 [
3074         case $cf_cv_system_name in #(vi
3075         OS/2*|os2*) #(vi
3076         LIB_PREFIX=''
3077         ;;
3078         *)      LIB_PREFIX='lib'
3079         ;;
3080         esac
3081 ifelse($1,,,[$1=$LIB_PREFIX])
3082         AC_SUBST(LIB_PREFIX)
3083 ])dnl
3084 dnl ---------------------------------------------------------------------------
3085 dnl CF_LIB_RULES version: 74 updated: 2013/09/07 13:54:05
3086 dnl ------------
3087 dnl Append definitions and rules for the given models to the subdirectory
3088 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3089 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3090 dnl the corresponding makefile to list the models that we'll generate.
3091 dnl
3092 dnl For shared libraries, make a list of symbolic links to construct when
3093 dnl generating each library.  The convention used for Linux is the simplest
3094 dnl one:
3095 dnl     lib<name>.so    ->
3096 dnl     lib<name>.so.<major>    ->
3097 dnl     lib<name>.so.<maj>.<minor>
3098 dnl
3099 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3100 AC_DEFUN([CF_LIB_RULES],
3101 [
3102 cf_prefix=$LIB_PREFIX
3103 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3104
3105 case $cf_cv_shlib_version in #(vi
3106 cygdll|msysdll|mingw)
3107         TINFO_NAME=$TINFO_ARG_SUFFIX
3108         TINFO_SUFFIX=.dll
3109         ;;
3110 esac
3111
3112 if test -n "$TINFO_SUFFIX" ; then
3113         case $TINFO_SUFFIX in
3114         tw*)
3115                 TINFO_NAME="${TINFO_NAME}tw"
3116                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw//'`
3117                 ;;
3118         t*)
3119                 TINFO_NAME="${TINFO_NAME}t"
3120                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t//'`
3121                 ;;
3122         w*)
3123                 TINFO_NAME="${TINFO_NAME}w"
3124                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w//'`
3125                 ;;
3126         esac
3127 fi
3128
3129 for cf_dir in $SRC_SUBDIRS
3130 do
3131         if test ! -d $srcdir/$cf_dir ; then
3132                 continue
3133         elif test -f $srcdir/$cf_dir/modules; then
3134
3135                 SHARED_LIB=
3136                 Libs_To_Make=
3137                 for cf_item in $cf_LIST_MODELS
3138                 do
3139                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3140                         cf_libname=$cf_dir
3141                         test "$cf_dir" = c++ && cf_libname=ncurses++
3142                         if test $cf_item = shared ; then
3143                                 if test -n "${LIB_SUFFIX}"
3144                                 then
3145                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${LIB_SUFFIX}"'//'`
3146                                 else
3147                                         cf_shared_suffix="$cf_suffix"
3148                                 fi
3149                                 if test "$cf_cv_do_symlinks" = yes ; then
3150                                         cf_version_name=
3151
3152                                         case "$cf_cv_shlib_version" in #(vi
3153                                         rel) #(vi
3154                                                 cf_version_name=REL_VERSION
3155                                                 ;;
3156                                         abi)
3157                                                 cf_version_name=ABI_VERSION
3158                                                 ;;
3159                                         esac
3160
3161                                         if test -n "$cf_version_name"
3162                                         then
3163                                                 case "$cf_cv_system_name" in #(vi
3164                                                 darwin*)
3165                                                         # "w", etc?
3166                                                         cf_suffix="${LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3167                                                         ;; #(vi
3168                                                 *)
3169                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3170                                                         ;;
3171                                                 esac
3172                                         fi
3173                                         if test -n "${LIB_SUFFIX}"
3174                                         then
3175                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${LIB_SUFFIX}"'//'`
3176                                         else
3177                                                 cf_shared_suffix="$cf_suffix"
3178                                         fi
3179                                 fi
3180                                 # cygwin needs import library, and has unique naming convention
3181                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3182                                 # use 'cyg' prefix for shared lib.
3183                                 case $cf_cv_shlib_version in #(vi
3184                                 cygdll) #(vi
3185                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3186                                         Libs_To_Make="$Libs_To_Make ../lib/cyg${cf_libname}${cf_cygsuf}"
3187                                         continue
3188                                         ;;
3189                                 msysdll) #(vi
3190                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3191                                         Libs_To_Make="$Libs_To_Make ../lib/msys-${cf_libname}${cf_cygsuf}"
3192                                         continue
3193                                         ;;
3194                                 mingw)
3195                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3196                                         Libs_To_Make="$Libs_To_Make ../lib/lib${cf_libname}${cf_cygsuf}"
3197                                         continue
3198                                         ;;
3199                                 esac
3200                         fi
3201                         Libs_To_Make="$Libs_To_Make ../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3202                 done
3203
3204                 if test $cf_dir = ncurses ; then
3205                         cf_subsets="$LIB_SUBSETS"
3206                         cf_r_parts="$cf_subsets"
3207                         cf_liblist="$Libs_To_Make"
3208
3209                         while test -n "$cf_r_parts"
3210                         do
3211                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3212                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3213                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3214                                         cf_item=
3215                                         case $cf_l_parts in #(vi
3216                                         *termlib*) #(vi
3217                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3218                                                 ;;
3219                                         *ticlib*)
3220                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3221                                                 ;;
3222                                         *)
3223                                                 break
3224                                                 ;;
3225                                         esac
3226                                         if test -n "$cf_item"; then
3227                                                 Libs_To_Make="$cf_item $Libs_To_Make"
3228                                         fi
3229                                 else
3230                                         break
3231                                 fi
3232                         done
3233                 else
3234                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3235                 fi
3236
3237                 if test $cf_dir = c++; then
3238                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3239                                 cf_list=
3240                                 for cf_item in $Libs_To_Make
3241                                 do
3242                                         case $cf_item in
3243                                         *.a)
3244                                                 ;;
3245                                         *)
3246                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3247                                                 ;;
3248                                         esac
3249                                         for cf_test in $cf_list
3250                                         do
3251                                                 if test "$cf_test" = "$cf_item"
3252                                                 then
3253                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3254                                                         cf_item=
3255                                                         break
3256                                                 fi
3257                                         done
3258                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3259                                 done
3260                                 Libs_To_Make="$cf_list"
3261                         fi
3262                 fi
3263
3264                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3265                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3266                         $cf_dir/Makefile >$cf_dir/Makefile.out
3267                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3268
3269                 $AWK -f $srcdir/mk-0th.awk \
3270                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3271                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3272
3273                 for cf_subset in $cf_subsets
3274                 do
3275                         cf_subdirs=
3276                         for cf_item in $cf_LIST_MODELS
3277                         do
3278
3279                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3280                         CF_UPPER(cf_ITEM,$cf_item)
3281
3282                         CXX_MODEL=$cf_ITEM
3283                         if test "$CXX_MODEL" = SHARED; then
3284                                 case $cf_cv_shlib_version in #(vi
3285                                 cygdll|msysdll|mingw) #(vi
3286                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3287                                         with_shared_cxx=yes
3288                                         ;;
3289                                 *)
3290                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3291                                         ;;
3292                                 esac
3293                         fi
3294
3295                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3296                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3297
3298                         # Test for case where we build libtinfo with a different name.
3299                         cf_libname=$cf_dir
3300                         if test $cf_dir = ncurses ; then
3301                                 case $cf_subset in
3302                                 *base*)
3303                                         cf_libname=${cf_libname}$LIB_SUFFIX
3304                                         ;;
3305                                 *termlib*)
3306                                         cf_libname=$TINFO_LIB_SUFFIX
3307                                         ;;
3308                                 ticlib*)
3309                                         cf_libname=$TICS_LIB_SUFFIX
3310                                         ;;
3311                                 esac
3312                         elif test $cf_dir = c++ ; then
3313                                 cf_libname=ncurses++$LIB_SUFFIX
3314                         else
3315                                 cf_libname=${cf_libname}$LIB_SUFFIX
3316                         fi
3317                         if test -n "${DFT_ARG_SUFFIX}" ; then
3318                                 # undo $LIB_SUFFIX add-on in CF_LIB_SUFFIX
3319                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${LIB_SUFFIX}%%"`
3320                         fi
3321
3322                         # These dependencies really are for development, not
3323                         # builds, but they are useful in porting, too.
3324                         cf_depend="../include/ncurses_cfg.h"
3325                         if test "$srcdir" = "."; then
3326                                 cf_reldir="."
3327                         else
3328                                 cf_reldir="\${srcdir}"
3329                         fi
3330
3331                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3332                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3333                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3334                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3335                         fi
3336
3337                         cf_dir_suffix=
3338                         old_cf_suffix="$cf_suffix"
3339                         if test "$cf_cv_shlib_version_infix" = yes ; then
3340                         if test -n "$LIB_SUFFIX" ; then
3341                                 case $LIB_SUFFIX in
3342                                 tw*)
3343                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
3344                                         cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3345                                         cf_dir_suffix=tw
3346                                         ;;
3347                                 t*)
3348                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
3349                                         cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3350                                         cf_dir_suffix=t
3351                                         ;;
3352                                 w*)
3353                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
3354                                         cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3355                                         cf_dir_suffix=w
3356                                         ;;
3357                                 esac
3358                         fi
3359                         fi
3360
3361                         $AWK -f $srcdir/mk-1st.awk \
3362                                 name=${cf_libname}${cf_dir_suffix} \
3363                                 traces=$LIB_TRACING \
3364                                 MODEL=$cf_ITEM \
3365                                 CXX_MODEL=$CXX_MODEL \
3366                                 model=$cf_subdir \
3367                                 prefix=$cf_prefix \
3368                                 suffix=$cf_suffix \
3369                                 subset=$cf_subset \
3370                                 driver=$cf_cv_term_driver \
3371                                 SymLink="$LN_S" \
3372                                 TermlibRoot=$TINFO_NAME \
3373                                 TermlibSuffix=$TINFO_SUFFIX \
3374                                 ShlibVer=$cf_cv_shlib_version \
3375                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3376                                 ReLink=${cf_cv_do_relink:-no} \
3377                                 DoLinks=$cf_cv_do_symlinks \
3378                                 rmSoLocs=$cf_cv_rm_so_locs \
3379                                 ldconfig="$LDCONFIG" \
3380                                 overwrite=$WITH_OVERWRITE \
3381                                 depend="$cf_depend" \
3382                                 host="$host" \
3383                                 libtool_version="$LIBTOOL_VERSION" \
3384                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3385
3386                         cf_suffix="$old_cf_suffix"
3387
3388                         for cf_subdir2 in $cf_subdirs lib
3389                         do
3390                                 test $cf_subdir = $cf_subdir2 && break
3391                         done
3392                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3393                         $AWK -f $srcdir/mk-2nd.awk \
3394                                 name=$cf_dir \
3395                                 traces=$LIB_TRACING \
3396                                 MODEL=$cf_ITEM \
3397                                 model=$cf_subdir \
3398                                 subset=$cf_subset \
3399                                 srcdir=$srcdir \
3400                                 echo=$WITH_ECHO \
3401                                 crenames=$cf_cv_prog_CC_c_o \
3402                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3403                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3404                         cf_subdirs="$cf_subdirs $cf_subdir"
3405                         done
3406                 done
3407         fi
3408
3409         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
3410 done
3411
3412 for cf_dir in $SRC_SUBDIRS
3413 do
3414         if test ! -d $srcdir/$cf_dir ; then
3415                 continue
3416         fi
3417
3418         if test -f $cf_dir/Makefile ; then
3419                 case "$cf_dir" in
3420                 Ada95) #(vi
3421                         echo 'libs \' >> Makefile
3422                         echo 'install.libs \' >> Makefile
3423                         echo 'uninstall.libs ::' >> Makefile
3424                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
3425                         ;;
3426                 esac
3427         fi
3428
3429         if test -f $srcdir/$cf_dir/modules; then
3430                 echo >> Makefile
3431                 if test -f $srcdir/$cf_dir/headers; then
3432 cat >> Makefile <<CF_EOF
3433 install.includes \\
3434 uninstall.includes \\
3435 CF_EOF
3436                 fi
3437 if test "$cf_dir" != "c++" ; then
3438 echo 'lint \' >> Makefile
3439 fi
3440 cat >> Makefile <<CF_EOF
3441 libs \\
3442 lintlib \\
3443 install.libs \\
3444 uninstall.libs \\
3445 install.$cf_dir \\
3446 uninstall.$cf_dir ::
3447         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3448 CF_EOF
3449         elif test -f $srcdir/$cf_dir/headers; then
3450 cat >> Makefile <<CF_EOF
3451
3452 libs \\
3453 install.libs \\
3454 uninstall.libs \\
3455 install.includes \\
3456 uninstall.includes ::
3457         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3458 CF_EOF
3459 fi
3460 done
3461
3462 if test "x$cf_with_db_install" = xyes; then
3463 cat >> Makefile <<CF_EOF
3464
3465 install.libs uninstall.libs \\
3466 install.data uninstall.data ::
3467 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3468 CF_EOF
3469 fi
3470
3471 if test "x$cf_with_manpages" = xyes; then
3472 cat >> Makefile <<CF_EOF
3473
3474 install.man \\
3475 uninstall.man ::
3476         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
3477 CF_EOF
3478 fi
3479
3480 cat >> Makefile <<CF_EOF
3481
3482 distclean ::
3483         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3484         rm -f headers.sh headers.sed mk_shared_lib.sh
3485         rm -f edit_man.* man_alias.*
3486         rm -rf \${DIRS_TO_MAKE}
3487 CF_EOF
3488
3489 # Special case: tack's manpage lives in its own directory.
3490 if test "x$cf_with_manpages" = xyes; then
3491 if test -d tack ; then
3492 if test -f $srcdir/$tack.h; then
3493 cat >> Makefile <<CF_EOF
3494
3495 install.man \\
3496 uninstall.man ::
3497         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
3498 CF_EOF
3499 fi
3500 fi
3501 fi
3502
3503 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3504 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3505 dnl anything, and will make it more standardized.  It's awkward to decide this
3506 dnl at configuration because of quoting, so we'll simply make all headers
3507 dnl installed via a script that can do the right thing.
3508
3509 rm -f headers.sed headers.sh
3510
3511 dnl ( generating this script makes the makefiles a little tidier :-)
3512 echo creating headers.sh
3513 cat >headers.sh <<CF_EOF
3514 #! /bin/sh
3515 # This shell script is generated by the 'configure' script.  It is invoked in a
3516 # subdirectory of the build tree.  It generates a sed-script in the parent
3517 # directory that is used to adjust includes for header files that reside in a
3518 # subdirectory of /usr/include, etc.
3519 PRG=""
3520 while test \[$]# != 3
3521 do
3522 PRG="\$PRG \[$]1"; shift
3523 done
3524 DST=\[$]1
3525 REF=\[$]2
3526 SRC=\[$]3
3527 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3528 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3529 echo installing \$SRC in \$DST
3530 CF_EOF
3531
3532 if test $WITH_CURSES_H = yes; then
3533         cat >>headers.sh <<CF_EOF
3534 case \$DST in
3535 /*/include/*)
3536         END=\`basename \$DST\`
3537         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3538         do
3539                 NAME=\`basename \$i\`
3540                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3541         done
3542         ;;
3543 *)
3544         echo "" >> \$TMPSED
3545         ;;
3546 esac
3547 CF_EOF
3548
3549 else
3550         cat >>headers.sh <<CF_EOF
3551 case \$DST in
3552 /*/include/*)
3553         END=\`basename \$DST\`
3554         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3555         do
3556                 NAME=\`basename \$i\`
3557                 if test "\$NAME" = "curses.h"
3558                 then
3559                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3560                         NAME=ncurses.h
3561                 fi
3562                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3563         done
3564         ;;
3565 *)
3566         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3567         ;;
3568 esac
3569 CF_EOF
3570 fi
3571 cat >>headers.sh <<CF_EOF
3572 rm -f \$TMPSRC
3573 sed -f \$TMPSED \$SRC > \$TMPSRC
3574 NAME=\`basename \$SRC\`
3575 CF_EOF
3576 if test $WITH_CURSES_H != yes; then
3577         cat >>headers.sh <<CF_EOF
3578 test "\$NAME" = "curses.h" && NAME=ncurses.h
3579 CF_EOF
3580 fi
3581 cat >>headers.sh <<CF_EOF
3582 # Just in case someone gzip'd manpages, remove the conflicting copy.
3583 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3584
3585 eval \$PRG \$TMPSRC \$DST/\$NAME
3586 rm -f \$TMPSRC \$TMPSED
3587 CF_EOF
3588
3589 chmod 0755 headers.sh
3590
3591 for cf_dir in $SRC_SUBDIRS
3592 do
3593         if test ! -d $srcdir/$cf_dir ; then
3594                 continue
3595         fi
3596
3597         if test -f $srcdir/$cf_dir/headers; then
3598                 $AWK -f $srcdir/mk-hdr.awk \
3599                         subset="$LIB_SUBSETS" \
3600                         compat="$WITH_CURSES_H" \
3601                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3602         fi
3603
3604         if test -f $srcdir/$cf_dir/modules; then
3605                 if test "$cf_dir" != "c++" ; then
3606                         cat >>$cf_dir/Makefile <<"CF_EOF"
3607 depend : ${AUTO_SRC}
3608         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3609
3610 # DO NOT DELETE THIS LINE -- make depend depends on it.
3611 CF_EOF
3612                 fi
3613         fi
3614 done
3615 AC_SUBST(Libs_To_Make)
3616 ])dnl
3617 dnl ---------------------------------------------------------------------------
3618 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3619 dnl -------------
3620 dnl Find the and soname for the given shared library.  Set the cache variable
3621 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3622 dnl variable to "unknown".
3623 dnl
3624 dnl $1 = headers
3625 dnl $2 = code
3626 dnl $3 = library name
3627 AC_DEFUN([CF_LIB_SONAME],
3628 [
3629 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3630
3631 cf_cv_$3_soname=unknown
3632 if test "$cross_compiling" != yes ; then
3633 cat >conftest.$ac_ext <<CF_EOF
3634 $1
3635 int main()
3636 {
3637 $2
3638         ${cf_cv_main_return:-return}(0);
3639 }
3640 CF_EOF
3641 cf_save_LIBS="$LIBS"
3642         CF_ADD_LIB($3)
3643         if AC_TRY_EVAL(ac_compile) ; then
3644                 if AC_TRY_EVAL(ac_link) ; then
3645                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3646                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3647                 fi
3648         fi
3649 rm -rf conftest*
3650 LIBS="$cf_save_LIBS"
3651 fi
3652 ])
3653 ])
3654 dnl ---------------------------------------------------------------------------
3655 dnl CF_LIB_SUFFIX version: 22 updated: 2013/09/07 13:54:05
3656 dnl -------------
3657 dnl Compute the library file-suffix from the given model name
3658 dnl $1 = model name
3659 dnl $2 = variable to set (the nominal library suffix)
3660 dnl $3 = dependency variable to set (actual filename)
3661 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3662 AC_DEFUN([CF_LIB_SUFFIX],
3663 [
3664         case X$1 in #(vi
3665         Xlibtool) #(vi
3666                 $2='.la'
3667                 $3=[$]$2
3668                 ;;
3669         Xdebug) #(vi
3670                 $2='_g.a'
3671                 $3=[$]$2
3672                 ;;
3673         Xprofile) #(vi
3674                 $2='_p.a'
3675                 $3=[$]$2
3676                 ;;
3677         Xshared) #(vi
3678                 case $cf_cv_system_name in
3679                 aix[[5-7]]*) #(vi
3680                         $2='.a'
3681                         $3=[$]$2
3682                         ;;
3683                 cygwin*|msys*|mingw*) #(vi
3684                         $2='.dll'
3685                         $3='.dll.a'
3686                         ;;
3687                 darwin*) #(vi
3688                         $2='.dylib'
3689                         $3=[$]$2
3690                         ;;
3691                 hpux*) #(vi
3692                         case $target in
3693                         ia64*) #(vi
3694                                 $2='.so'
3695                                 $3=[$]$2
3696                                 ;;
3697                         *) #(vi
3698                                 $2='.sl'
3699                                 $3=[$]$2
3700                                 ;;
3701                         esac
3702                         ;;
3703                 *) #(vi
3704                         $2='.so'
3705                         $3=[$]$2
3706                         ;;
3707                 esac
3708                 ;;
3709         *)
3710                 $2='.a'
3711                 $3=[$]$2
3712                 ;;
3713         esac
3714         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3715         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
3716 ])dnl
3717 dnl ---------------------------------------------------------------------------
3718 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
3719 dnl -----------
3720 dnl Compute the string to append to -library from the given model name
3721 dnl $1 = model name
3722 dnl $2 = variable to set
3723 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3724 AC_DEFUN([CF_LIB_TYPE],
3725 [
3726         case $1 in
3727         libtool) $2=''   ;;
3728         normal)  $2=''   ;;
3729         debug)   $2='_g' ;;
3730         profile) $2='_p' ;;
3731         shared)  $2=''   ;;
3732         esac
3733         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3734 ])dnl
3735 dnl ---------------------------------------------------------------------------
3736 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
3737 dnl ----------------
3738 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3739 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3740 dnl have to provide wrappers for global tables to ensure they're linked
3741 dnl properly.
3742 AC_DEFUN([CF_LINK_DATAONLY],
3743 [
3744 AC_MSG_CHECKING([if data-only library module links])
3745 AC_CACHE_VAL(cf_cv_link_dataonly,[
3746         rm -f conftest.a
3747         cat >conftest.$ac_ext <<EOF
3748 #line __oline__ "configure"
3749 int     testdata[[3]] = { 123, 456, 789 };
3750 EOF
3751         if AC_TRY_EVAL(ac_compile) ; then
3752                 mv conftest.o data.o && \
3753                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3754         fi
3755         rm -f conftest.$ac_ext data.o
3756         cat >conftest.$ac_ext <<EOF
3757 #line __oline__ "configure"
3758 int     testfunc()
3759 {
3760 #if defined(NeXT)
3761         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3762 #else
3763         extern int testdata[[3]];
3764         return testdata[[0]] == 123
3765            &&  testdata[[1]] == 456
3766            &&  testdata[[2]] == 789;
3767 #endif
3768 }
3769 EOF
3770         if AC_TRY_EVAL(ac_compile); then
3771                 mv conftest.o func.o && \
3772                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3773         fi
3774         rm -f conftest.$ac_ext func.o
3775         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3776         cf_saveLIBS="$LIBS"
3777         LIBS="conftest.a $LIBS"
3778         AC_TRY_RUN([
3779         int main()
3780         {
3781                 extern int testfunc();
3782                 ${cf_cv_main_return:-return} (!testfunc());
3783         }
3784         ],
3785         [cf_cv_link_dataonly=yes],
3786         [cf_cv_link_dataonly=no],
3787         [cf_cv_link_dataonly=unknown])
3788         LIBS="$cf_saveLIBS"
3789         ])
3790 AC_MSG_RESULT($cf_cv_link_dataonly)
3791
3792 if test "$cf_cv_link_dataonly" = no ; then
3793         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
3794         BROKEN_LINKER=1
3795 fi
3796
3797 ])dnl
3798 dnl ---------------------------------------------------------------------------
3799 dnl CF_LINK_FUNCS version: 8 updated: 2012/10/06 17:56:13
3800 dnl -------------
3801 dnl Most Unix systems have both link and symlink, a few don't have symlink.
3802 dnl A few non-Unix systems implement symlink, but not link.
3803 dnl A few non-systems implement neither (or have nonfunctional versions).
3804 AC_DEFUN([CF_LINK_FUNCS],
3805 [
3806 AC_CHECK_FUNCS( \
3807         remove \
3808         unlink )
3809
3810 if test "$cross_compiling" = yes ; then
3811         AC_CHECK_FUNCS( \
3812                 link \
3813                 symlink )
3814 else
3815         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
3816                 cf_cv_link_funcs=
3817                 for cf_func in link symlink ; do
3818                         AC_TRY_RUN([
3819 #include <sys/types.h>
3820 #include <sys/stat.h>
3821 #ifdef HAVE_UNISTD_H
3822 #include <unistd.h>
3823 #endif
3824 int main()
3825 {
3826         int fail = 0;
3827         char *src = "config.log";
3828         char *dst = "conftest.chk";
3829         struct stat src_sb;
3830         struct stat dst_sb;
3831
3832         stat(src, &src_sb);
3833         fail = ($cf_func("config.log", "conftest.chk") < 0)
3834             || (stat(dst, &dst_sb) < 0)
3835             || (dst_sb.st_mtime != src_sb.st_mtime);
3836 #ifdef HAVE_UNLINK
3837         unlink(dst);
3838 #else
3839         remove(dst);
3840 #endif
3841         ${cf_cv_main_return:-return} (fail);
3842 }
3843                         ],[
3844                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
3845                         eval 'ac_cv_func_'$cf_func'=yes'],[
3846                         eval 'ac_cv_func_'$cf_func'=no'],[
3847                         eval 'ac_cv_func_'$cf_func'=error'])
3848                 done
3849                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
3850         ])
3851         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
3852         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
3853 fi
3854 ])dnl
3855 dnl ---------------------------------------------------------------------------
3856 dnl CF_MAKEFLAGS version: 15 updated: 2014/05/10 16:43:23
3857 dnl ------------
3858 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
3859 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
3860 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
3861 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
3862 AC_DEFUN([CF_MAKEFLAGS],
3863 [
3864 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
3865         cf_cv_makeflags=''
3866         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
3867         do
3868                 cat >cf_makeflags.tmp <<CF_EOF
3869 SHELL = /bin/sh
3870 all :
3871         @ echo '.$cf_option'
3872 CF_EOF
3873                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
3874                 case "$cf_result" in
3875                 .*k|.*kw)
3876                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
3877                         case "$cf_result" in
3878                         .*CC=*) cf_cv_makeflags=
3879                                 ;;
3880                         *)      cf_cv_makeflags=$cf_option
3881                                 ;;
3882                         esac
3883                         break
3884                         ;;
3885                 .-)     ;;
3886                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
3887                         ;;
3888                 esac
3889         done
3890         rm -f cf_makeflags.tmp
3891 ])
3892
3893 AC_SUBST(cf_cv_makeflags)
3894 ])dnl
3895 dnl ---------------------------------------------------------------------------
3896 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
3897 dnl ------------
3898 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
3899 dnl a monocase filesystem.
3900 AC_DEFUN([CF_MAKE_TAGS],[
3901 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
3902
3903 AC_CHECK_PROGS(CTAGS, exctags ctags)
3904 AC_CHECK_PROGS(ETAGS, exetags etags)
3905
3906 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
3907
3908 if test "$cf_cv_mixedcase" = yes ; then
3909         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
3910 else
3911         MAKE_UPPER_TAGS=no
3912 fi
3913
3914 if test "$MAKE_UPPER_TAGS" = yes ; then
3915         MAKE_UPPER_TAGS=
3916 else
3917         MAKE_UPPER_TAGS="#"
3918 fi
3919
3920 if test "$MAKE_LOWER_TAGS" = yes ; then
3921         MAKE_LOWER_TAGS=
3922 else
3923         MAKE_LOWER_TAGS="#"
3924 fi
3925
3926 AC_SUBST(CTAGS)
3927 AC_SUBST(ETAGS)
3928
3929 AC_SUBST(MAKE_UPPER_TAGS)
3930 AC_SUBST(MAKE_LOWER_TAGS)
3931 ])dnl
3932 dnl ---------------------------------------------------------------------------
3933 dnl CF_MANPAGE_FORMAT version: 9 updated: 2010/10/23 16:10:30
3934 dnl -----------------
3935 dnl Option to allow user to override automatic configuration of manpage format.
3936 dnl There are several special cases:
3937 dnl
3938 dnl     gzip - man checks for, can display gzip'd files
3939 dnl     compress - man checks for, can display compressed files
3940 dnl     BSDI - files in the cat-directories are suffixed ".0"
3941 dnl     formatted - installer should format (put files in cat-directory)
3942 dnl     catonly - installer should only format, e.g., for a turnkey system.
3943 dnl
3944 dnl There are other configurations which this macro does not test, e.g., HPUX's
3945 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
3946 dnl convention would not match our use).
3947 AC_DEFUN([CF_MANPAGE_FORMAT],
3948 [
3949 AC_REQUIRE([CF_PATHSEP])
3950 AC_MSG_CHECKING(format of man-pages)
3951
3952 AC_ARG_WITH(manpage-format,
3953         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
3954                           optionally formatted/catonly, e.g., gzip,formatted],
3955         [MANPAGE_FORMAT=$withval],
3956         [MANPAGE_FORMAT=unknown])
3957
3958 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
3959 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
3960
3961 cf_unknown=
3962
3963 case $MANPAGE_FORMAT in
3964 unknown)
3965   if test -z "$MANPATH" ; then
3966     MANPATH="/usr/man:/usr/share/man"
3967   fi
3968
3969   # look for the 'date' man-page (it's most likely to be installed!)
3970   MANPAGE_FORMAT=
3971   cf_preform=no
3972   cf_catonly=yes
3973   cf_example=date
3974
3975   IFS="${IFS:-  }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
3976   for cf_dir in $MANPATH; do
3977     test -z "$cf_dir" && cf_dir=/usr/man
3978     for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
3979     do
3980       cf_test=`echo $cf_name | sed -e 's/*//'`
3981       if test "x$cf_test" = "x$cf_name" ; then
3982
3983         case "$cf_name" in
3984         *.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
3985         *.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
3986         *.0)    MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
3987         *)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
3988         esac
3989
3990         case "$cf_name" in
3991         $cf_dir/man*)
3992           cf_catonly=no
3993           ;;
3994         $cf_dir/cat*)
3995           cf_preform=yes
3996           ;;
3997         esac
3998         break
3999       fi
4000
4001       # if we found a match in either man* or cat*, stop looking
4002       if test -n "$MANPAGE_FORMAT" ; then
4003         cf_found=no
4004         test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
4005         test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
4006         case "$cf_name" in
4007         $cf_dir/cat*)
4008           cf_found=yes
4009           ;;
4010         esac
4011         test $cf_found=yes && break
4012       fi
4013     done
4014     # only check the first directory in $MANPATH where we find manpages
4015     if test -n "$MANPAGE_FORMAT" ; then
4016        break
4017     fi
4018   done
4019   # if we did not find the example, just assume it is normal
4020   test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
4021   IFS="$ac_save_ifs"
4022   ;;
4023 *)
4024   for cf_option in $MANPAGE_FORMAT; do
4025      case $cf_option in #(vi
4026      gzip|compress|BSDI|normal|formatted|catonly)
4027        ;;
4028      *)
4029        cf_unknown="$cf_unknown $cf_option"
4030        ;;
4031      esac
4032   done
4033   ;;
4034 esac
4035
4036 AC_MSG_RESULT($MANPAGE_FORMAT)
4037 if test -n "$cf_unknown" ; then
4038   AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
4039 fi
4040 ])dnl
4041 dnl ---------------------------------------------------------------------------
4042 dnl CF_MANPAGE_RENAMES version: 7 updated: 2005/06/18 18:51:57
4043 dnl ------------------
4044 dnl The Debian people have their own naming convention for manpages.  This
4045 dnl option lets us override the name of the file containing renaming, or
4046 dnl disable it altogether.
4047 AC_DEFUN([CF_MANPAGE_RENAMES],
4048 [
4049 AC_MSG_CHECKING(for manpage renaming)
4050
4051 AC_ARG_WITH(manpage-renames,
4052         [  --with-manpage-renames  specify manpage-renaming],
4053         [MANPAGE_RENAMES=$withval],
4054         [MANPAGE_RENAMES=yes])
4055
4056 case ".$MANPAGE_RENAMES" in #(vi
4057 .no) #(vi
4058   ;;
4059 .|.yes)
4060   # Debian 'man' program?
4061   if test -f /etc/debian_version ; then
4062     MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
4063   else
4064     MANPAGE_RENAMES=no
4065   fi
4066   ;;
4067 esac
4068
4069 if test "$MANPAGE_RENAMES" != no ; then
4070   if test -f $srcdir/man/$MANPAGE_RENAMES ; then
4071     MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
4072   elif test ! -f $MANPAGE_RENAMES ; then
4073     AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
4074   fi
4075
4076   test ! -d man && mkdir man
4077
4078   # Construct a sed-script to perform renaming within man-pages
4079   if test -n "$MANPAGE_RENAMES" ; then
4080     test ! -d man && mkdir man
4081     sh $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
4082   fi
4083 fi
4084
4085 AC_MSG_RESULT($MANPAGE_RENAMES)
4086 AC_SUBST(MANPAGE_RENAMES)
4087 ])dnl
4088 dnl ---------------------------------------------------------------------------
4089 dnl CF_MANPAGE_SYMLINKS version: 5 updated: 2010/07/24 17:12:40
4090 dnl -------------------
4091 dnl Some people expect each tool to make all aliases for manpages in the
4092 dnl man-directory.  This accommodates the older, less-capable implementations
4093 dnl of 'man', and is optional.
4094 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4095 [
4096 AC_MSG_CHECKING(if manpage aliases will be installed)
4097
4098 AC_ARG_WITH(manpage-aliases,
4099         [  --with-manpage-aliases  specify manpage-aliases using .so],
4100         [MANPAGE_ALIASES=$withval],
4101         [MANPAGE_ALIASES=yes])
4102
4103 AC_MSG_RESULT($MANPAGE_ALIASES)
4104
4105 case "x$LN_S" in #(vi
4106 xln*) #(vi
4107         cf_use_symlinks=yes
4108         ;;
4109 *)
4110         cf_use_symlinks=no
4111         ;;
4112 esac
4113
4114 MANPAGE_SYMLINKS=no
4115 if test "$MANPAGE_ALIASES" = yes ; then
4116 AC_MSG_CHECKING(if manpage symlinks should be used)
4117
4118 AC_ARG_WITH(manpage-symlinks,
4119         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
4120         [MANPAGE_SYMLINKS=$withval],
4121         [MANPAGE_SYMLINKS=$cf_use_symlinks])
4122
4123 if test "$$cf_use_symlinks" = no; then
4124 if test "$MANPAGE_SYMLINKS" = yes ; then
4125         AC_MSG_WARN(cannot make symlinks, will use .so files)
4126         MANPAGE_SYMLINKS=no
4127 fi
4128 fi
4129
4130 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4131 fi
4132
4133 ])dnl
4134 dnl ---------------------------------------------------------------------------
4135 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4136 dnl --------------
4137 dnl This option causes manpages to be run through tbl(1) to generate tables
4138 dnl correctly.
4139 AC_DEFUN([CF_MANPAGE_TBL],
4140 [
4141 AC_MSG_CHECKING(for manpage tbl)
4142
4143 AC_ARG_WITH(manpage-tbl,
4144         [  --with-manpage-tbl      specify manpage processing with tbl],
4145         [MANPAGE_TBL=$withval],
4146         [MANPAGE_TBL=no])
4147
4148 AC_MSG_RESULT($MANPAGE_TBL)
4149 ])dnl
4150 dnl ---------------------------------------------------------------------------
4151 dnl CF_MAN_PAGES version: 43 updated: 2013/02/09 12:53:45
4152 dnl ------------
4153 dnl Try to determine if the man-pages on the system are compressed, and if
4154 dnl so, what format is used.  Use this information to construct a script that
4155 dnl will install man-pages.
4156 AC_DEFUN([CF_MAN_PAGES],
4157 [
4158 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4159 CF_MANPAGE_FORMAT
4160 CF_MANPAGE_RENAMES
4161 CF_MANPAGE_SYMLINKS
4162 CF_MANPAGE_TBL
4163
4164   if test "$prefix" = "NONE" ; then
4165      cf_prefix="$ac_default_prefix"
4166   else
4167      cf_prefix="$prefix"
4168   fi
4169
4170   case "$MANPAGE_FORMAT" in # (vi
4171   *catonly*) # (vi
4172     cf_format=yes
4173     cf_inboth=no
4174     ;;
4175   *formatted*) # (vi
4176     cf_format=yes
4177     cf_inboth=yes
4178     ;;
4179   *)
4180     cf_format=no
4181     cf_inboth=no
4182     ;;
4183   esac
4184
4185 test ! -d man && mkdir man
4186
4187 cf_so_strip=
4188 cf_compress=
4189 case "$MANPAGE_FORMAT" in #(vi
4190 *compress*) #(vi
4191         cf_so_strip="Z"
4192         cf_compress=compress
4193   ;;
4194 *gzip*)
4195         cf_so_strip="gz"
4196         cf_compress=gzip
4197   ;;
4198 esac
4199
4200 cf_edit_man=./edit_man.sh
4201 cf_man_alias=`pwd`/man_alias.sed
4202
4203 cat >$cf_edit_man <<CF_EOF
4204 #! /bin/sh
4205 # this script is generated by the configure-script CF_MAN_PAGES macro.
4206
4207 prefix="$cf_prefix"
4208 datarootdir="$datarootdir"
4209 datadir="$datadir"
4210
4211 NCURSES_MAJOR="$NCURSES_MAJOR"
4212 NCURSES_MINOR="$NCURSES_MINOR"
4213 NCURSES_PATCH="$NCURSES_PATCH"
4214
4215 NCURSES_OSPEED="$NCURSES_OSPEED"
4216 TERMINFO="$TERMINFO"
4217
4218 INSTALL="$INSTALL"
4219 INSTALL_DATA="$INSTALL_DATA"
4220
4221 transform="$program_transform_name"
4222
4223 TMP=\${TMPDIR:=/tmp}/man\$\$
4224 trap "rm -f \$TMP" 0 1 2 5 15
4225
4226 form=\[$]1
4227 shift || exit 1
4228
4229 verb=\[$]1
4230 shift || exit 1
4231
4232 mandir=\[$]1
4233 shift || exit 1
4234
4235 srcdir=\[$]1
4236 top_srcdir=\[$]srcdir/..
4237 shift || exit 1
4238
4239 if test "\$form" = normal ; then
4240         if test "$cf_format" = yes ; then
4241         if test "$cf_inboth" = no ; then
4242                 sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4243                 exit $?
4244         fi
4245         fi
4246         cf_subdir=\$mandir/man
4247         cf_tables=$MANPAGE_TBL
4248 else
4249         cf_subdir=\$mandir/cat
4250         cf_tables=yes
4251 fi
4252
4253 # process the list of source-files
4254 for i in \[$]* ; do
4255 case \$i in #(vi
4256 *.orig|*.rej) ;; #(vi
4257 *.[[0-9]]*)
4258         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4259         if test \$verb = installing ; then
4260         if test ! -d \$cf_subdir\${section} ; then
4261                 mkdir -p \$cf_subdir\$section
4262         fi
4263         fi
4264
4265         # replace variables in man page
4266         if test ! -f $cf_man_alias ; then
4267 cat >>$cf_man_alias <<-CF_EOF2
4268                 s,@DATADIR@,\$datadir,g
4269                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
4270                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
4271                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
4272                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
4273                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
4274                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
4275 CF_EOF
4276         ifelse($1,,,[
4277         for cf_name in $1
4278         do
4279                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4280                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4281 cat >>$cf_edit_man <<-CF_EOF
4282                 s,@$cf_NAME@,$cf_name,g
4283 CF_EOF
4284         done
4285         ])
4286 cat >>$cf_edit_man <<CF_EOF
4287 CF_EOF2
4288                 echo "...made $cf_man_alias"
4289         fi
4290
4291         aliases=
4292         cf_source=\`basename \$i\`
4293         inalias=\$cf_source
4294         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4295         if test ! -f \$inalias ; then
4296                 echo .. skipped \$cf_source
4297                 continue
4298         fi
4299 CF_EOF
4300
4301 if test "$MANPAGE_ALIASES" != no ; then
4302 cat >>$cf_edit_man <<CF_EOF
4303         nCurses=ignore.3x
4304         test $with_curses_h = yes && nCurses=ncurses.3x
4305         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4306 CF_EOF
4307 fi
4308
4309 if test "$MANPAGE_RENAMES" = no ; then
4310 cat >>$cf_edit_man <<CF_EOF
4311         # perform program transformations for section 1 man pages
4312         if test \$section = 1 ; then
4313                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4314         else
4315                 cf_target=\$cf_subdir\${section}/\$cf_source
4316         fi
4317 CF_EOF
4318 else
4319 cat >>$cf_edit_man <<CF_EOF
4320         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4321         if test -z "\$cf_target" ; then
4322                 echo '? missing rename for '\$cf_source
4323                 cf_target="\$cf_source"
4324         fi
4325         cf_target="\$cf_subdir\${section}/\${cf_target}"
4326
4327 CF_EOF
4328 fi
4329
4330 cat >>$cf_edit_man <<CF_EOF
4331         sed     -f $cf_man_alias \\
4332 CF_EOF
4333
4334 if test -f $MANPAGE_RENAMES ; then
4335 cat >>$cf_edit_man <<CF_EOF
4336                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4337 CF_EOF
4338 else
4339 cat >>$cf_edit_man <<CF_EOF
4340                 < \$i >\$TMP
4341 CF_EOF
4342 fi
4343
4344 cat >>$cf_edit_man <<CF_EOF
4345 if test \$cf_tables = yes ; then
4346         tbl \$TMP >\$TMP.out
4347         mv \$TMP.out \$TMP
4348 fi
4349 CF_EOF
4350
4351 if test $with_overwrite != yes ; then
4352 cat >>$cf_edit_man <<CF_EOF
4353         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
4354         mv \$TMP.out \$TMP
4355 CF_EOF
4356 fi
4357
4358 if test $with_curses_h != yes ; then
4359 cat >>$cf_edit_man <<CF_EOF
4360         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4361         mv \$TMP.out \$TMP
4362 CF_EOF
4363 fi
4364
4365 cat >>$cf_edit_man <<CF_EOF
4366         if test \$form = format ; then
4367                 nroff -man \$TMP >\$TMP.out
4368                 mv \$TMP.out \$TMP
4369         fi
4370 CF_EOF
4371
4372 if test -n "$cf_compress" ; then
4373 cat >>$cf_edit_man <<CF_EOF
4374         if test \$verb = installing ; then
4375         if ( $cf_compress -f \$TMP )
4376         then
4377                 mv \$TMP.$cf_so_strip \$TMP
4378         fi
4379         fi
4380         cf_target="\$cf_target.$cf_so_strip"
4381 CF_EOF
4382 fi
4383
4384 case "$MANPAGE_FORMAT" in #(vi
4385 *BSDI*)
4386 cat >>$cf_edit_man <<CF_EOF
4387         if test \$form = format ; then
4388                 # BSDI installs only .0 suffixes in the cat directories
4389                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
4390         fi
4391 CF_EOF
4392   ;;
4393 esac
4394
4395 cat >>$cf_edit_man <<CF_EOF
4396         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
4397         if test \$verb = installing ; then
4398                 echo \$verb \$cf_target
4399                 \$INSTALL_DATA \$TMP \$cf_target
4400                 test -d \$cf_subdir\${section} &&
4401                 test -n "\$aliases" && (
4402                         cd \$cf_subdir\${section} && (
4403                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
4404                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
4405                                 cf_target=\`basename \$cf_target\`
4406                                 for cf_alias in \$aliases
4407                                 do
4408                                         if test \$section = 1 ; then
4409                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4410                                         fi
4411
4412                                         if test "$MANPAGE_SYMLINKS" = yes ; then
4413                                                 if test -f \$cf_alias\${suffix} ; then
4414                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
4415                                                         then
4416                                                                 continue
4417                                                         fi
4418                                                 fi
4419                                                 echo .. \$verb alias \$cf_alias\${suffix}
4420 CF_EOF
4421 case "x$LN_S" in #(vi
4422 *-f) #(vi
4423 cat >>$cf_edit_man <<CF_EOF
4424                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4425 CF_EOF
4426         ;;
4427 *)
4428 cat >>$cf_edit_man <<CF_EOF
4429                                                 rm -f \$cf_alias\${suffix}
4430                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4431 CF_EOF
4432         ;;
4433 esac
4434 cat >>$cf_edit_man <<CF_EOF
4435                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
4436                                                 echo ".so \$cf_source" >\$TMP
4437 CF_EOF
4438 if test -n "$cf_compress" ; then
4439 cat >>$cf_edit_man <<CF_EOF
4440                                                 if test -n "$cf_so_strip" ; then
4441                                                         $cf_compress -f \$TMP
4442                                                         mv \$TMP.$cf_so_strip \$TMP
4443                                                 fi
4444 CF_EOF
4445 fi
4446 cat >>$cf_edit_man <<CF_EOF
4447                                                 echo .. \$verb alias \$cf_alias\${suffix}
4448                                                 rm -f \$cf_alias\${suffix}
4449                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
4450                                         fi
4451                                 done
4452                         )
4453                 )
4454         elif test \$verb = removing ; then
4455                 test -f \$cf_target && (
4456                         echo \$verb \$cf_target
4457                         rm -f \$cf_target
4458                 )
4459                 test -d \$cf_subdir\${section} &&
4460                 test -n "\$aliases" && (
4461                         cd \$cf_subdir\${section} && (
4462                                 for cf_alias in \$aliases
4463                                 do
4464                                         if test \$section = 1 ; then
4465                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4466                                         fi
4467
4468                                         echo .. \$verb alias \$cf_alias\${suffix}
4469                                         rm -f \$cf_alias\${suffix}
4470                                 done
4471                         )
4472                 )
4473         else
4474 #               echo ".hy 0"
4475                 cat \$TMP
4476         fi
4477         ;;
4478 esac
4479 done
4480
4481 if test $cf_inboth = yes ; then
4482 if test \$form != format ; then
4483         sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4484 fi
4485 fi
4486
4487 exit 0
4488 CF_EOF
4489 chmod 755 $cf_edit_man
4490
4491 ])dnl
4492 dnl ---------------------------------------------------------------------------
4493 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
4494 dnl -----------
4495 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
4496 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
4497 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
4498 AC_DEFUN([CF_MATH_LIB],
4499 [
4500 AC_CACHE_CHECK(if -lm needed for math functions,
4501         cf_cv_need_libm,[
4502         AC_TRY_LINK([
4503         #include <stdio.h>
4504         #include <math.h>
4505         ],
4506         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
4507         [cf_cv_need_libm=no],
4508         [cf_cv_need_libm=yes])])
4509 if test "$cf_cv_need_libm" = yes
4510 then
4511 ifelse($1,,[
4512         CF_ADD_LIB(m)
4513 ],[$1=-lm])
4514 fi
4515 ])
4516 dnl ---------------------------------------------------------------------------
4517 dnl CF_MIXEDCASE_FILENAMES version: 6 updated: 2013/10/08 17:47:05
4518 dnl ----------------------
4519 dnl Check if the file-system supports mixed-case filenames.  If we're able to
4520 dnl create a lowercase name and see it as uppercase, it doesn't support that.
4521 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
4522 [
4523 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
4524 if test "$cross_compiling" = yes ; then
4525         case $target_alias in #(vi
4526         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*) #(vi
4527                 cf_cv_mixedcase=no
4528                 ;;
4529         *)
4530                 cf_cv_mixedcase=yes
4531                 ;;
4532         esac
4533 else
4534         rm -f conftest CONFTEST
4535         echo test >conftest
4536         if test -f CONFTEST ; then
4537                 cf_cv_mixedcase=no
4538         else
4539                 cf_cv_mixedcase=yes
4540         fi
4541         rm -f conftest CONFTEST
4542 fi
4543 ])
4544 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
4545 ])dnl
4546 dnl ---------------------------------------------------------------------------
4547 dnl CF_MKSTEMP version: 9 updated: 2012/10/03 04:34:49
4548 dnl ----------
4549 dnl Check for a working mkstemp.  This creates two files, checks that they are
4550 dnl successfully created and distinct (AmigaOS apparently fails on the last).
4551 AC_DEFUN([CF_MKSTEMP],[
4552 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
4553 rm -rf conftest*
4554 AC_TRY_RUN([
4555 #include <sys/types.h>
4556 #include <stdlib.h>
4557 #include <stdio.h>
4558 #include <string.h>
4559 #include <sys/stat.h>
4560 int main()
4561 {
4562         char *tmpl = "conftestXXXXXX";
4563         char name[2][80];
4564         int n;
4565         int result = 0;
4566         int fd;
4567         struct stat sb;
4568
4569         umask(077);
4570         for (n = 0; n < 2; ++n) {
4571                 strcpy(name[n], tmpl);
4572                 if ((fd = mkstemp(name[n])) >= 0) {
4573                         if (!strcmp(name[n], tmpl)
4574                          || stat(name[n], &sb) != 0
4575                          || (sb.st_mode & S_IFMT) != S_IFREG
4576                          || (sb.st_mode & 077) != 0) {
4577                                 result = 1;
4578                         }
4579                         close(fd);
4580                 }
4581         }
4582         if (result == 0
4583          && !strcmp(name[0], name[1]))
4584                 result = 1;
4585         ${cf_cv_main_return:-return}(result);
4586 }
4587 ],[cf_cv_func_mkstemp=yes
4588 ],[cf_cv_func_mkstemp=no
4589 ],[cf_cv_func_mkstemp=maybe])
4590 ])
4591 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
4592         AC_CHECK_FUNC(mkstemp)
4593 fi
4594 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
4595         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
4596 fi
4597 ])dnl
4598 dnl ---------------------------------------------------------------------------
4599 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
4600 dnl ----------
4601 dnl Write a debug message to config.log, along with the line number in the
4602 dnl configure script.
4603 AC_DEFUN([CF_MSG_LOG],[
4604 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
4605 ])dnl
4606 dnl ---------------------------------------------------------------------------
4607 dnl CF_NCURSES_ABI_6 version: 1 updated: 2005/09/17 18:42:49
4608 dnl ----------------
4609 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
4610 dnl warn about this.
4611 AC_DEFUN([CF_NCURSES_ABI_6],[
4612 if test "${with_abi_version+set}" != set; then
4613         case $cf_cv_rel_version in
4614         5.*)
4615                 cf_cv_rel_version=6.0
4616                 cf_cv_abi_version=6
4617                 AC_MSG_WARN(Overriding ABI version to $cf_cv_abi_version)
4618                 ;;
4619         esac
4620 fi
4621 ])dnl
4622 dnl ---------------------------------------------------------------------------
4623 dnl CF_NO_LEAKS_OPTION version: 5 updated: 2012/10/02 20:55:03
4624 dnl ------------------
4625 dnl see CF_WITH_NO_LEAKS
4626 AC_DEFUN([CF_NO_LEAKS_OPTION],[
4627 AC_MSG_CHECKING(if you want to use $1 for testing)
4628 AC_ARG_WITH($1,
4629         [$2],
4630         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
4631          $4
4632 ])
4633         : ${with_cflags:=-g}
4634         : ${with_no_leaks:=yes}
4635          with_$1=yes],
4636         [with_$1=])
4637 AC_MSG_RESULT(${with_$1:-no})
4638
4639 case .$with_cflags in #(vi
4640 .*-g*)
4641         case .$CFLAGS in #(vi
4642         .*-g*) #(vi
4643                 ;;
4644         *)
4645                 CF_ADD_CFLAGS([-g])
4646                 ;;
4647         esac
4648         ;;
4649 esac
4650 ])dnl
4651 dnl ---------------------------------------------------------------------------
4652 dnl CF_NUMBER_SYNTAX version: 1 updated: 2003/09/20 18:12:49
4653 dnl ----------------
4654 dnl Check if the given variable is a number.  If not, report an error.
4655 dnl $1 is the variable
4656 dnl $2 is the message
4657 AC_DEFUN([CF_NUMBER_SYNTAX],[
4658 if test -n "$1" ; then
4659   case $1 in #(vi
4660   [[0-9]]*) #(vi
4661         ;;
4662   *)
4663         AC_MSG_ERROR($2 is not a number: $1)
4664         ;;
4665   esac
4666 else
4667   AC_MSG_ERROR($2 value is empty)
4668 fi
4669 ])dnl
4670 dnl ---------------------------------------------------------------------------
4671 dnl CF_OBJ_SUBDIR version: 6 updated: 2013/09/07 14:06:10
4672 dnl -------------
4673 dnl Compute the object-directory name from the given model name
4674 AC_DEFUN([CF_OBJ_SUBDIR],
4675 [
4676         case $1 in
4677         libtool) $2='obj_lo'  ;;
4678         normal)  $2='objects' ;;
4679         debug)   $2='obj_g' ;;
4680         profile) $2='obj_p' ;;
4681         shared)
4682                 case $cf_cv_system_name in #(vi
4683                 cygwin|msys) #(vi
4684                         $2='objects' ;;
4685                 *)
4686                         $2='obj_s' ;;
4687                 esac
4688         esac
4689 ])dnl
4690 dnl ---------------------------------------------------------------------------
4691 dnl CF_PATHSEP version: 6 updated: 2012/09/29 18:38:12
4692 dnl ----------
4693 dnl Provide a value for the $PATH and similar separator (or amend the value
4694 dnl as provided in autoconf 2.5x).
4695 AC_DEFUN([CF_PATHSEP],
4696 [
4697         AC_MSG_CHECKING(for PATH separator)
4698         case $cf_cv_system_name in
4699         os2*)   PATH_SEPARATOR=';'  ;;
4700         *)      ${PATH_SEPARATOR:=':'}  ;;
4701         esac
4702 ifelse([$1],,,[$1=$PATH_SEPARATOR])
4703         AC_SUBST(PATH_SEPARATOR)
4704         AC_MSG_RESULT($PATH_SEPARATOR)
4705 ])dnl
4706 dnl ---------------------------------------------------------------------------
4707 dnl CF_PATH_SYNTAX version: 14 updated: 2012/06/19 20:58:54
4708 dnl --------------
4709 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
4710 dnl begins with one of the prefix/exec_prefix variables, and then again if the
4711 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
4712 dnl delayed evaluation of those symbols.
4713 AC_DEFUN([CF_PATH_SYNTAX],[
4714 if test "x$prefix" != xNONE; then
4715   cf_path_syntax="$prefix"
4716 else
4717   cf_path_syntax="$ac_default_prefix"
4718 fi
4719
4720 case ".[$]$1" in #(vi
4721 .\[$]\(*\)*|.\'*\'*) #(vi
4722   ;;
4723 ..|./*|.\\*) #(vi
4724   ;;
4725 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
4726   ;;
4727 .\[$]{*prefix}*|.\[$]{*dir}*) #(vi
4728   eval $1="[$]$1"
4729   case ".[$]$1" in #(vi
4730   .NONE/*)
4731     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4732     ;;
4733   esac
4734   ;; #(vi
4735 .no|.NONE/*)
4736   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4737   ;;
4738 *)
4739   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
4740   ;;
4741 esac
4742 ])dnl
4743 dnl ---------------------------------------------------------------------------
4744 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
4745 dnl -------------
4746 dnl Check for the package-config program, unless disabled by command-line.
4747 AC_DEFUN([CF_PKG_CONFIG],
4748 [
4749 AC_MSG_CHECKING(if you want to use pkg-config)
4750 AC_ARG_WITH(pkg-config,
4751         [  --with-pkg-config{=path} enable/disable use of pkg-config],
4752         [cf_pkg_config=$withval],
4753         [cf_pkg_config=yes])
4754 AC_MSG_RESULT($cf_pkg_config)
4755
4756 case $cf_pkg_config in #(vi
4757 no) #(vi
4758         PKG_CONFIG=none
4759         ;;
4760 yes) #(vi
4761         CF_ACVERSION_CHECK(2.52,
4762                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
4763                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
4764         ;;
4765 *)
4766         PKG_CONFIG=$withval
4767         ;;
4768 esac
4769
4770 test -z "$PKG_CONFIG" && PKG_CONFIG=none
4771 if test "$PKG_CONFIG" != none ; then
4772         CF_PATH_SYNTAX(PKG_CONFIG)
4773 fi
4774
4775 AC_SUBST(PKG_CONFIG)
4776 ])dnl
4777 dnl ---------------------------------------------------------------------------
4778 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
4779 dnl -----------------
4780 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
4781 dnl
4782 dnl     POSIX.1-1990                            _POSIX_SOURCE
4783 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
4784 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
4785 dnl             Bindings Option
4786 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
4787 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
4788 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
4789 dnl
4790 dnl Parameters:
4791 dnl     $1 is the nominal value for _POSIX_C_SOURCE
4792 AC_DEFUN([CF_POSIX_C_SOURCE],
4793 [
4794 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
4795
4796 cf_save_CFLAGS="$CFLAGS"
4797 cf_save_CPPFLAGS="$CPPFLAGS"
4798
4799 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
4800 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
4801
4802 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
4803         CF_MSG_LOG(if the symbol is already defined go no further)
4804         AC_TRY_COMPILE([#include <sys/types.h>],[
4805 #ifndef _POSIX_C_SOURCE
4806 make an error
4807 #endif],
4808         [cf_cv_posix_c_source=no],
4809         [cf_want_posix_source=no
4810          case .$cf_POSIX_C_SOURCE in #(vi
4811          .[[12]]??*) #(vi
4812                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4813                 ;;
4814          .2) #(vi
4815                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4816                 cf_want_posix_source=yes
4817                 ;;
4818          .*)
4819                 cf_want_posix_source=yes
4820                 ;;
4821          esac
4822          if test "$cf_want_posix_source" = yes ; then
4823                 AC_TRY_COMPILE([#include <sys/types.h>],[
4824 #ifdef _POSIX_SOURCE
4825 make an error
4826 #endif],[],
4827                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
4828          fi
4829          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
4830          CFLAGS="$cf_trim_CFLAGS"
4831          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
4832          CF_MSG_LOG(if the second compile does not leave our definition intact error)
4833          AC_TRY_COMPILE([#include <sys/types.h>],[
4834 #ifndef _POSIX_C_SOURCE
4835 make an error
4836 #endif],,
4837          [cf_cv_posix_c_source=no])
4838          CFLAGS="$cf_save_CFLAGS"
4839          CPPFLAGS="$cf_save_CPPFLAGS"
4840         ])
4841 ])
4842
4843 if test "$cf_cv_posix_c_source" != no ; then
4844         CFLAGS="$cf_trim_CFLAGS"
4845         CPPFLAGS="$cf_trim_CPPFLAGS"
4846         CF_ADD_CFLAGS($cf_cv_posix_c_source)
4847 fi
4848
4849 ])dnl
4850 dnl ---------------------------------------------------------------------------
4851 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
4852 dnl ------------
4853 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
4854 dnl
4855 dnl $1 = symbol to test
4856 dnl $2 = value (if any) to use for a predefinition
4857 AC_DEFUN([CF_PREDEFINE],
4858 [
4859 AC_MSG_CHECKING(if we must define $1)
4860 AC_TRY_COMPILE([#include <sys/types.h>
4861 ],[
4862 #ifndef $1
4863 make an error
4864 #endif],[cf_result=no],[cf_result=yes])
4865 AC_MSG_RESULT($cf_result)
4866
4867 if test "$cf_result" = yes ; then
4868         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
4869 elif test "x$2" != "x" ; then
4870         AC_MSG_CHECKING(checking for compatible value versus $2)
4871         AC_TRY_COMPILE([#include <sys/types.h>
4872 ],[
4873 #if $1-$2 < 0
4874 make an error
4875 #endif],[cf_result=yes],[cf_result=no])
4876         AC_MSG_RESULT($cf_result)
4877         if test "$cf_result" = no ; then
4878                 # perhaps we can override it - try...
4879                 CPPFLAGS="$CPPFLAGS -D$1=$2"
4880         fi
4881 fi
4882 ])dnl
4883 dnl ---------------------------------------------------------------------------
4884 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
4885 dnl ------------
4886 dnl Append definitions and rules for the given programs to the subdirectory
4887 dnl Makefiles, and the recursion rule for the top-level Makefile.
4888 dnl
4889 dnl parameters
4890 dnl     $1 = script to run
4891 dnl     $2 = list of subdirectories
4892 dnl
4893 dnl variables
4894 dnl     $AWK
4895 AC_DEFUN([CF_PRG_RULES],
4896 [
4897 for cf_dir in $2
4898 do
4899         if test ! -d $srcdir/$cf_dir; then
4900                 continue
4901         elif test -f $srcdir/$cf_dir/programs; then
4902                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
4903         fi
4904 done
4905
4906 ])dnl
4907 dnl ---------------------------------------------------------------------------
4908 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
4909 dnl ----------
4910 dnl Check for archiver "ar".
4911 AC_DEFUN([CF_PROG_AR],[
4912 AC_CHECK_TOOL(AR, ar, ar)
4913 ])
4914 dnl ---------------------------------------------------------------------------
4915 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
4916 dnl -----------
4917 dnl Check for awk, ensure that the check found something.
4918 AC_DEFUN([CF_PROG_AWK],
4919 [
4920 AC_PROG_AWK
4921 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
4922 ])dnl
4923 dnl ---------------------------------------------------------------------------
4924 dnl CF_PROG_CC version: 3 updated: 2012/10/06 15:31:55
4925 dnl ----------
4926 dnl standard check for CC, plus followup sanity checks
4927 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
4928 AC_DEFUN([CF_PROG_CC],[
4929 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
4930 CF_GCC_VERSION
4931 CF_ACVERSION_CHECK(2.52,
4932         [AC_PROG_CC_STDC],
4933         [CF_ANSI_CC_REQD])
4934 CF_CC_ENV_FLAGS
4935 ])dnl
4936 dnl ---------------------------------------------------------------------------
4937 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
4938 dnl --------------
4939 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
4940 dnl the output file can be renamed, and allows for a shell variable that can
4941 dnl be used later.  The parameter is either CC or CXX.  The result is the
4942 dnl cache variable:
4943 dnl     $cf_cv_prog_CC_c_o
4944 dnl     $cf_cv_prog_CXX_c_o
4945 AC_DEFUN([CF_PROG_CC_C_O],
4946 [AC_REQUIRE([AC_PROG_CC])dnl
4947 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
4948 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
4949 [
4950 cat > conftest.$ac_ext <<CF_EOF
4951 #include <stdio.h>
4952 int main()
4953 {
4954         ${cf_cv_main_return:-return}(0);
4955 }
4956 CF_EOF
4957 # We do the test twice because some compilers refuse to overwrite an
4958 # existing .o file with -o, though they will create one.
4959 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
4960 if AC_TRY_EVAL(ac_try) &&
4961   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
4962 then
4963   eval cf_cv_prog_$1_c_o=yes
4964 else
4965   eval cf_cv_prog_$1_c_o=no
4966 fi
4967 rm -rf conftest*
4968 ])dnl
4969 if test $cf_cv_prog_$1_c_o = yes; then
4970   AC_MSG_RESULT([yes])
4971 else
4972   AC_MSG_RESULT([no])
4973 fi
4974 ])dnl
4975 dnl ---------------------------------------------------------------------------
4976 dnl CF_PROG_EGREP version: 1 updated: 2006/09/16 11:40:59
4977 dnl -------------
4978 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
4979 dnl This macro adds a check to ensure the script found something.
4980 AC_DEFUN([CF_PROG_EGREP],
4981 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
4982    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
4983     then ac_cv_prog_egrep='grep -E'
4984     else ac_cv_prog_egrep='egrep'
4985     fi])
4986  EGREP=$ac_cv_prog_egrep
4987  AC_SUBST([EGREP])
4988 test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
4989 ])dnl
4990 dnl ---------------------------------------------------------------------------
4991 dnl CF_PROG_GNAT version: 2 updated: 2011/10/22 14:01:47
4992 dnl ------------
4993 dnl Check for gnatmake, ensure that it is complete.
4994 AC_DEFUN([CF_PROG_GNAT],[
4995 cf_ada_make=gnatmake
4996 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
4997 if test "$ac_cv_prog_gnat_exists" = no; then
4998    cf_ada_make=
4999    cf_cv_prog_gnat_correct=no
5000 else
5001    CF_GNAT_VERSION
5002    AC_CHECK_PROG(M4_exists, m4, yes, no)
5003    if test "$ac_cv_prog_M4_exists" = no; then
5004       cf_cv_prog_gnat_correct=no
5005       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
5006    fi
5007    if test "$cf_cv_prog_gnat_correct" = yes; then
5008       AC_MSG_CHECKING(if GNAT works)
5009       CF_GNAT_TRY_RUN([procedure conftest;],
5010 [with Text_IO;
5011 with GNAT.OS_Lib;
5012 procedure conftest is
5013 begin
5014    Text_IO.Put ("Hello World");
5015    Text_IO.New_Line;
5016    GNAT.OS_Lib.OS_Exit (0);
5017 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
5018       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
5019    fi
5020 fi
5021
5022 AC_SUBST(cf_ada_make)
5023 ])dnl
5024 dnl ---------------------------------------------------------------------------
5025 dnl CF_PROG_INSTALL version: 5 updated: 2002/12/21 22:46:07
5026 dnl ---------------
5027 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
5028 dnl misc/tabset install won't work properly.  Usually this happens only when
5029 dnl using the fallback mkinstalldirs script
5030 AC_DEFUN([CF_PROG_INSTALL],
5031 [AC_PROG_INSTALL
5032 case $INSTALL in
5033 /*)
5034   ;;
5035 *)
5036   CF_DIRNAME(cf_dir,$INSTALL)
5037   test -z "$cf_dir" && cf_dir=.
5038   INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
5039   ;;
5040 esac
5041 ])dnl
5042 dnl ---------------------------------------------------------------------------
5043 dnl CF_PROG_LDCONFIG version: 3 updated: 2011/06/04 20:09:13
5044 dnl ----------------
5045 dnl Check for ldconfig, needed to fixup shared libraries that would be built
5046 dnl and then used in the install.
5047 AC_DEFUN([CF_PROG_LDCONFIG],[
5048 if test "$cross_compiling" = yes ; then
5049   LDCONFIG=:
5050 else
5051 case "$cf_cv_system_name" in #(vi
5052 dragonfly*|mirbsd*|freebsd*) #(vi
5053   test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
5054   ;;
5055 *) LDPATH=$PATH:/sbin:/usr/sbin
5056   AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
5057   ;;
5058 esac
5059 fi
5060 AC_SUBST(LDCONFIG)
5061 ])dnl
5062 dnl ---------------------------------------------------------------------------
5063 dnl CF_PROG_LINT version: 2 updated: 2009/08/12 04:43:14
5064 dnl ------------
5065 AC_DEFUN([CF_PROG_LINT],
5066 [
5067 AC_CHECK_PROGS(LINT, tdlint lint alint splint lclint)
5068 AC_SUBST(LINT_OPTS)
5069 ])dnl
5070 dnl ---------------------------------------------------------------------------
5071 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
5072 dnl ------------
5073 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
5074 dnl option if it is supported.
5075 AC_DEFUN([CF_PROG_LN_S],[
5076 AC_PROG_LN_S
5077 AC_MSG_CHECKING(if $LN_S -f options work)
5078
5079 rm -f conf$$.src conf$$dst
5080 echo >conf$$.dst
5081 echo first >conf$$.src
5082 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
5083         cf_prog_ln_sf=yes
5084 else
5085         cf_prog_ln_sf=no
5086 fi
5087 rm -f conf$$.dst conf$$src
5088 AC_MSG_RESULT($cf_prog_ln_sf)
5089
5090 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
5091 ])dnl
5092 dnl ---------------------------------------------------------------------------
5093 dnl CF_REGEX version: 10 updated: 2012/10/04 20:12:20
5094 dnl --------
5095 dnl Attempt to determine if we've got one of the flavors of regular-expression
5096 dnl code that we can support.
5097 AC_DEFUN([CF_REGEX],
5098 [
5099
5100 cf_regex_func=no
5101
5102 cf_regex_libs="regex re"
5103 case $host_os in #(vi
5104 mingw*)
5105         cf_regex_libs="gnurx $cf_regex_libs"
5106         ;;
5107 esac
5108
5109 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
5110         for cf_regex_lib in $cf_regex_libs
5111         do
5112                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
5113                                 CF_ADD_LIB($cf_regex_lib)
5114                                 cf_regex_func=regcomp
5115                                 break])
5116         done
5117 ])
5118
5119 if test "$cf_regex_func" = no ; then
5120         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
5121                 AC_CHECK_LIB(gen,compile,[
5122                                 CF_ADD_LIB(gen)
5123                                 cf_regex_func=compile])])
5124 fi
5125
5126 if test "$cf_regex_func" = no ; then
5127         AC_MSG_WARN(cannot find regular expression library)
5128 fi
5129
5130 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
5131
5132 cf_cv_regex_hdrs=no
5133 case $cf_regex_func in #(vi
5134 compile) #(vi
5135         for cf_regex_hdr in regexp.h regexpr.h
5136         do
5137                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
5138                         char *p = compile("", "", "", 0);
5139                         int x = step("", "");
5140                 ],[
5141                         cf_cv_regex_hdrs=$cf_regex_hdr
5142                         break
5143                 ])
5144         done
5145         ;;
5146 *)
5147         for cf_regex_hdr in regex.h
5148         do
5149                 AC_TRY_LINK([#include <sys/types.h>
5150 #include <$cf_regex_hdr>],[
5151                         regex_t *p;
5152                         int x = regcomp(p, "", 0);
5153                         int y = regexec(p, "", 0, 0, 0);
5154                         regfree(p);
5155                 ],[
5156                         cf_cv_regex_hdrs=$cf_regex_hdr
5157                         break
5158                 ])
5159         done
5160         ;;
5161 esac
5162
5163 ])
5164
5165 case $cf_cv_regex_hdrs in #(vi
5166     no)        AC_MSG_WARN(no regular expression header found) ;; #(vi
5167     regex.h)   AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;; #(vi
5168     regexp.h)  AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;; #(vi
5169     regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
5170 esac
5171 ])dnl
5172 dnl ---------------------------------------------------------------------------
5173 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
5174 dnl ----------------
5175 dnl Remove all -U and -D options that refer to the given symbol from a list
5176 dnl of C compiler options.  This works around the problem that not all
5177 dnl compilers process -U and -D options from left-to-right, so a -U option
5178 dnl cannot be used to cancel the effect of a preceding -D option.
5179 dnl
5180 dnl $1 = target (which could be the same as the source variable)
5181 dnl $2 = source (including '$')
5182 dnl $3 = symbol to remove
5183 define([CF_REMOVE_DEFINE],
5184 [
5185 $1=`echo "$2" | \
5186         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
5187                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
5188 ])dnl
5189 dnl ---------------------------------------------------------------------------
5190 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
5191 dnl -------------
5192 dnl Remove the given library from the symbol
5193 dnl
5194 dnl $1 = target (which could be the same as the source variable)
5195 dnl $2 = source (including '$')
5196 dnl $3 = library to remove
5197 define([CF_REMOVE_LIB],
5198 [
5199 # remove $3 library from $2
5200 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5201 ])dnl
5202 dnl ---------------------------------------------------------------------------
5203 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
5204 dnl -------------
5205 AC_DEFUN([CF_RPATH_HACK],
5206 [
5207 AC_REQUIRE([CF_LD_RPATH_OPT])
5208 AC_MSG_CHECKING(for updated LDFLAGS)
5209 if test -n "$LD_RPATH_OPT" ; then
5210         AC_MSG_RESULT(maybe)
5211
5212         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5213         cf_rpath_list="/usr/lib /lib"
5214         if test "$cf_ldd_prog" != no
5215         then
5216                 cf_rpath_oops=
5217
5218 AC_TRY_LINK([#include <stdio.h>],
5219                 [printf("Hello");],
5220                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
5221                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
5222
5223                 # If we passed the link-test, but get a "not found" on a given library,
5224                 # this could be due to inept reconfiguration of gcc to make it only
5225                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
5226                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
5227                 # /usr/local libraries.
5228                 if test -n "$cf_rpath_oops"
5229                 then
5230                         for cf_rpath_src in $cf_rpath_oops
5231                         do
5232                                 for cf_rpath_dir in \
5233                                         /usr/local \
5234                                         /usr/pkg \
5235                                         /opt/sfw
5236                                 do
5237                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
5238                                         then
5239                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
5240                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
5241                                                 break
5242                                         fi
5243                                 done
5244                         done
5245                 fi
5246         fi
5247
5248         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5249
5250         CF_RPATH_HACK_2(LDFLAGS)
5251         CF_RPATH_HACK_2(LIBS)
5252
5253         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5254 else
5255         AC_MSG_RESULT(no)
5256 fi
5257 AC_SUBST(EXTRA_LDFLAGS)
5258 ])dnl
5259 dnl ---------------------------------------------------------------------------
5260 dnl CF_RPATH_HACK_2 version: 6 updated: 2010/04/17 16:31:24
5261 dnl ---------------
5262 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
5263 dnl EXTRA_LDFLAGS for each -L option found.
5264 dnl
5265 dnl $cf_rpath_list contains a list of directories to ignore.
5266 dnl
5267 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
5268 dnl      but LIBS often has misplaced -L options.
5269 AC_DEFUN([CF_RPATH_HACK_2],
5270 [
5271 CF_VERBOSE(...checking $1 [$]$1)
5272
5273 cf_rpath_dst=
5274 for cf_rpath_src in [$]$1
5275 do
5276         case $cf_rpath_src in #(vi
5277         -L*) #(vi
5278
5279                 # check if this refers to a directory which we will ignore
5280                 cf_rpath_skip=no
5281                 if test -n "$cf_rpath_list"
5282                 then
5283                         for cf_rpath_item in $cf_rpath_list
5284                         do
5285                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
5286                                 then
5287                                         cf_rpath_skip=yes
5288                                         break
5289                                 fi
5290                         done
5291                 fi
5292
5293                 if test "$cf_rpath_skip" = no
5294                 then
5295                         # transform the option
5296                         if test "$LD_RPATH_OPT" = "-R " ; then
5297                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
5298                         else
5299                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
5300                         fi
5301
5302                         # if we have not already added this, add it now
5303                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
5304                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
5305                         then
5306                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
5307                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
5308                         fi
5309                 fi
5310                 ;;
5311         esac
5312         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
5313 done
5314 $1=$cf_rpath_dst
5315
5316 CF_VERBOSE(...checked $1 [$]$1)
5317 AC_SUBST(EXTRA_LDFLAGS)
5318 ])dnl
5319 dnl ---------------------------------------------------------------------------
5320 dnl CF_SHARED_OPTS version: 84 updated: 2013/11/03 06:26:10
5321 dnl --------------
5322 dnl --------------
5323 dnl Attempt to determine the appropriate CC/LD options for creating a shared
5324 dnl library.
5325 dnl
5326 dnl Notes:
5327 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
5328 dnl the build-tree, i.e., by making use of the libraries that are compiled in
5329 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
5330 dnl shared library since that can lead to unexpected results at runtime.
5331 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
5332 dnl libraries are compiled in ../../lib
5333 dnl
5334 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
5335 dnl to install symbolic links to the rel/abi versions of shared libraries.
5336 dnl
5337 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
5338 dnl version when making symbolic links.
5339 dnl
5340 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
5341 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
5342 dnl (ex: libncurses.so.<ver>).
5343 dnl
5344 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
5345 AC_DEFUN([CF_SHARED_OPTS],
5346 [
5347         AC_REQUIRE([CF_LD_RPATH_OPT])
5348         RM_SHARED_OPTS=
5349         LOCAL_LDFLAGS=
5350         LOCAL_LDFLAGS2=
5351         LD_SHARED_OPTS=
5352         INSTALL_LIB="-m 644"
5353         : ${rel_builddir:=.}
5354
5355         shlibdir=$libdir
5356         AC_SUBST(shlibdir)
5357
5358         MAKE_DLLS="#"
5359         AC_SUBST(MAKE_DLLS)
5360
5361         cf_cv_do_symlinks=no
5362         cf_ld_rpath_opt=
5363         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
5364
5365         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
5366         AC_ARG_WITH(shlib-version,
5367         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
5368         [test -z "$withval" && withval=auto
5369         case $withval in #(vi
5370         yes) #(vi
5371                 cf_cv_shlib_version=auto
5372                 ;;
5373         rel|abi|auto|no) #(vi
5374                 cf_cv_shlib_version=$withval
5375                 ;;
5376         *)
5377                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
5378                 ;;
5379         esac
5380         ],[cf_cv_shlib_version=auto])
5381         AC_MSG_RESULT($cf_cv_shlib_version)
5382
5383         cf_cv_rm_so_locs=no
5384         cf_try_cflags=
5385
5386         # Some less-capable ports of gcc support only -fpic
5387         CC_SHARED_OPTS=
5388         if test "$GCC" = yes
5389         then
5390                 AC_MSG_CHECKING(which $CC option to use)
5391                 cf_save_CFLAGS="$CFLAGS"
5392                 for CC_SHARED_OPTS in -fPIC -fpic ''
5393                 do
5394                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
5395                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
5396                 done
5397                 AC_MSG_RESULT($CC_SHARED_OPTS)
5398                 CFLAGS="$cf_save_CFLAGS"
5399         fi
5400
5401         cf_cv_shlib_version_infix=no
5402
5403         case $cf_cv_system_name in #(vi
5404         aix4.[3-9]*|aix[[5-7]]*) #(vi
5405                 if test "$GCC" = yes; then
5406                         CC_SHARED_OPTS=
5407                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5408                 else
5409                         # CC_SHARED_OPTS='-qpic=large -G'
5410                         # perhaps "-bM:SRE -bnoentry -bexpall"
5411                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5412                 fi
5413                 ;;
5414         beos*) #(vi
5415                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
5416                 ;;
5417         cygwin*) #(vi
5418                 CC_SHARED_OPTS=
5419                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5420                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5421                 cf_cv_shlib_version=cygdll
5422                 cf_cv_shlib_version_infix=cygdll
5423                 shlibdir=$bindir
5424                 MAKE_DLLS=
5425                 cat >mk_shared_lib.sh <<-CF_EOF
5426                 #!/bin/sh
5427                 SHARED_LIB=\[$]1
5428                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5429                 shift
5430                 cat <<-EOF
5431                 Linking shared library
5432                 ** SHARED_LIB \[$]SHARED_LIB
5433                 ** IMPORT_LIB \[$]IMPORT_LIB
5434 EOF
5435                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5436 CF_EOF
5437                 chmod +x mk_shared_lib.sh
5438                 ;;
5439         msys*) #(vi
5440                 CC_SHARED_OPTS=
5441                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5442                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5443                 cf_cv_shlib_version=msysdll
5444                 cf_cv_shlib_version_infix=msysdll
5445                 shlibdir=$bindir
5446                 MAKE_DLLS=
5447                 cat >mk_shared_lib.sh <<-CF_EOF
5448                 #!/bin/sh
5449                 SHARED_LIB=\[$]1
5450                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5451                 shift
5452                 cat <<-EOF
5453                 Linking shared library
5454                 ** SHARED_LIB \[$]SHARED_LIB
5455                 ** IMPORT_LIB \[$]IMPORT_LIB
5456 EOF
5457                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5458 CF_EOF
5459                 chmod +x mk_shared_lib.sh
5460                 ;;
5461         darwin*) #(vi
5462                 cf_try_cflags="no-cpp-precomp"
5463                 CC_SHARED_OPTS="-dynamic"
5464                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
5465                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
5466                 cf_cv_shlib_version_infix=yes
5467                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
5468                         cf_save_LDFLAGS=$LDFLAGS
5469                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5470                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
5471                                 LDFLAGS=$cf_save_LDFLAGS])
5472                 if test $cf_cv_ldflags_search_paths_first = yes; then
5473                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5474                 fi
5475                 ;;
5476         hpux[[7-8]]*) #(vi
5477                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
5478                 if test "$GCC" != yes; then
5479                         CC_SHARED_OPTS='+Z'
5480                 fi
5481                 MK_SHARED_LIB='${LD} -b -o $[@]'
5482                 INSTALL_LIB="-m 555"
5483                 ;;
5484         hpux*) #(vi
5485                 # (tested with gcc 2.7.2 -- I don't have c89)
5486                 if test "$GCC" = yes; then
5487                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
5488                 else
5489                         CC_SHARED_OPTS='+Z'
5490                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
5491                 fi
5492                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
5493                 # HP-UX shared libraries must be executable, and should be
5494                 # readonly to exploit a quirk in the memory manager.
5495                 INSTALL_LIB="-m 555"
5496                 ;;
5497         interix*)
5498                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5499                 if test "$cf_cv_shlib_version" = rel; then
5500                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
5501                 else
5502                         cf_shared_soname='`basename $@`'
5503                 fi
5504                 CC_SHARED_OPTS=
5505                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
5506                 ;;
5507         irix*) #(vi
5508                 if test "$cf_cv_enable_rpath" = yes ; then
5509                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5510                 fi
5511                 # tested with IRIX 5.2 and 'cc'.
5512                 if test "$GCC" != yes; then
5513                         CC_SHARED_OPTS='-KPIC'
5514                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
5515                 else
5516                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
5517                 fi
5518                 cf_cv_rm_so_locs=yes
5519                 ;;
5520         linux*|gnu*|k*bsd*-gnu) #(vi
5521                 if test "$DFT_LWR_MODEL" = "shared" ; then
5522                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5523                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5524                 fi
5525                 if test "$cf_cv_enable_rpath" = yes ; then
5526                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5527                 fi
5528                 CF_SHARED_SONAME
5529                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5530                 ;;
5531         mingw*) #(vi
5532                 cf_cv_shlib_version=mingw
5533                 cf_cv_shlib_version_infix=mingw
5534                 shlibdir=$bindir
5535                 MAKE_DLLS=
5536                 if test "$DFT_LWR_MODEL" = "shared" ; then
5537                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
5538                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5539                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
5540                 fi
5541                 CC_SHARED_OPTS=
5542                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5543                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5544                 cat >mk_shared_lib.sh <<-CF_EOF
5545                 #!/bin/sh
5546                 SHARED_LIB=\[$]1
5547                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5548                 shift
5549                 cat <<-EOF
5550                 Linking shared library
5551                 ** SHARED_LIB \[$]SHARED_LIB
5552                 ** IMPORT_LIB \[$]IMPORT_LIB
5553 EOF
5554                 exec \[$]* -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5555 CF_EOF
5556                 chmod +x mk_shared_lib.sh
5557                 ;;
5558         openbsd[[2-9]].*|mirbsd*) #(vi
5559                 if test "$DFT_LWR_MODEL" = "shared" ; then
5560                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5561                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5562                 fi
5563                 if test "$cf_cv_enable_rpath" = yes ; then
5564                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5565                 fi
5566                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5567                 CF_SHARED_SONAME
5568                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5569                 ;;
5570         nto-qnx*|openbsd*|freebsd[[12]].*) #(vi
5571                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5572                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
5573                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5574                 ;;
5575         dragonfly*|freebsd*) #(vi
5576                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5577                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5578                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5579                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
5580                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5581                 fi
5582                 CF_SHARED_SONAME
5583                 MK_SHARED_LIB='${LD} -shared -Bshareable -soname=`basename $[@]` -o $[@]'
5584                 ;;
5585         netbsd*) #(vi
5586                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5587                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5588                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5589                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5590                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5591                         if test "$cf_cv_shlib_version" = auto; then
5592                         if test -f /usr/libexec/ld.elf_so; then
5593                                 cf_cv_shlib_version=abi
5594                         else
5595                                 cf_cv_shlib_version=rel
5596                         fi
5597                         fi
5598                         CF_SHARED_SONAME
5599                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
5600                 else
5601                         MK_SHARED_LIB='${CC} -Wl,-shared -Wl,-Bshareable -o $[@]'
5602                 fi
5603                 ;;
5604         osf*|mls+*) #(vi
5605                 # tested with OSF/1 V3.2 and 'cc'
5606                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
5607                 # link with shared libs).
5608                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
5609                 case $host_os in #(vi
5610                 osf4*)
5611                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
5612                         ;;
5613                 esac
5614                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
5615                 if test "$DFT_LWR_MODEL" = "shared" ; then
5616                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5617                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5618                 fi
5619                 cf_cv_rm_so_locs=yes
5620                 ;;
5621         sco3.2v5*)  # (also uw2* and UW7: hops 13-Apr-98
5622                 # tested with osr5.0.5
5623                 if test "$GCC" != yes; then
5624                         CC_SHARED_OPTS='-belf -KPIC'
5625                 fi
5626                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
5627                 if test "$cf_cv_enable_rpath" = yes ; then
5628                         # only way is to set LD_RUN_PATH but no switch for it
5629                         RUN_PATH=$libdir
5630                 fi
5631                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5632                 LINK_PROGS='LD_RUN_PATH=${libdir}'
5633                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
5634                 ;;
5635         sunos4*) #(vi
5636                 # tested with SunOS 4.1.1 and gcc 2.7.0
5637                 if test "$GCC" != yes; then
5638                         CC_SHARED_OPTS='-KPIC'
5639                 fi
5640                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
5641                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5642                 ;;
5643         solaris2*) #(vi
5644                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
5645                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
5646                 if test "$DFT_LWR_MODEL" = "shared" ; then
5647                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
5648                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5649                 fi
5650                 if test "$cf_cv_enable_rpath" = yes ; then
5651                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
5652                 fi
5653                 CF_SHARED_SONAME
5654                 if test "$GCC" != yes; then
5655                         cf_save_CFLAGS="$CFLAGS"
5656                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
5657                         do
5658                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
5659                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
5660                         done
5661                         CFLAGS="$cf_save_CFLAGS"
5662                         CC_SHARED_OPTS=$cf_shared_opts
5663                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5664                 else
5665                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5666                 fi
5667                 ;;
5668         sysv5uw7*|unix_sv*) #(vi
5669                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
5670                 if test "$GCC" != yes; then
5671                         CC_SHARED_OPTS='-KPIC'
5672                 fi
5673                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
5674                 ;;
5675         *)
5676                 CC_SHARED_OPTS='unknown'
5677                 MK_SHARED_LIB='echo unknown'
5678                 ;;
5679         esac
5680
5681         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
5682         case "$cf_cv_shlib_version" in #(vi
5683         rel|abi)
5684                 case "$MK_SHARED_LIB" in #(vi
5685                 *'-o $[@]') #(vi
5686                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
5687                         ;;
5688                 *)
5689                         AC_MSG_WARN(ignored --with-shlib-version)
5690                         ;;
5691                 esac
5692                 ;;
5693         esac
5694
5695         if test -n "$cf_try_cflags"
5696         then
5697 cat > conftest.$ac_ext <<EOF
5698 #line __oline__ "${as_me:-configure}"
5699 #include <stdio.h>
5700 int main(int argc, char *argv[[]])
5701 {
5702         printf("hello\n");
5703         return (argv[[argc-1]] == 0) ;
5704 }
5705 EOF
5706                 cf_save_CFLAGS="$CFLAGS"
5707                 for cf_opt in $cf_try_cflags
5708                 do
5709                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
5710                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
5711                         if AC_TRY_EVAL(ac_compile); then
5712                                 AC_MSG_RESULT(yes)
5713                                 cf_save_CFLAGS="$CFLAGS"
5714                         else
5715                                 AC_MSG_RESULT(no)
5716                         fi
5717                 done
5718                 CFLAGS="$cf_save_CFLAGS"
5719         fi
5720
5721
5722         # RPATH_LIST is a colon-separated list of directories
5723         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
5724         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
5725
5726         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
5727
5728         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
5729         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
5730
5731         AC_SUBST(CC_SHARED_OPTS)
5732         AC_SUBST(LD_RPATH_OPT)
5733         AC_SUBST(LD_SHARED_OPTS)
5734         AC_SUBST(MK_SHARED_LIB)
5735         AC_SUBST(RM_SHARED_OPTS)
5736
5737         AC_SUBST(LINK_PROGS)
5738         AC_SUBST(LINK_TESTS)
5739
5740         AC_SUBST(EXTRA_LDFLAGS)
5741         AC_SUBST(LOCAL_LDFLAGS)
5742         AC_SUBST(LOCAL_LDFLAGS2)
5743
5744         AC_SUBST(INSTALL_LIB)
5745         AC_SUBST(RPATH_LIST)
5746 ])dnl
5747 dnl ---------------------------------------------------------------------------
5748 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
5749 dnl ----------------
5750 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
5751 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
5752 dnl option.
5753 dnl
5754 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
5755 dnl If missing, use "rel".
5756 define([CF_SHARED_SONAME],
5757 [
5758         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
5759         if test "$cf_cv_shlib_version" = rel; then
5760                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
5761         else
5762                 cf_cv_shared_soname='`basename $[@]`'
5763         fi
5764 ])
5765 dnl ---------------------------------------------------------------------------
5766 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
5767 dnl -----------
5768 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
5769 dnl programs need this test).
5770 dnl
5771 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
5772 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
5773 dnl winsize declaration is left alone - we may revisit this if Apple choose to
5774 dnl break that part of the interface as well.
5775 AC_DEFUN([CF_SIGWINCH],
5776 [
5777 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
5778         AC_TRY_COMPILE([
5779 #include <sys/types.h>
5780 #include <sys/signal.h>
5781 ],[int x = SIGWINCH],
5782         [cf_cv_define_sigwinch=yes],
5783         [AC_TRY_COMPILE([
5784 #undef _XOPEN_SOURCE
5785 #undef _POSIX_SOURCE
5786 #undef _POSIX_C_SOURCE
5787 #include <sys/types.h>
5788 #include <sys/signal.h>
5789 ],[int x = SIGWINCH],
5790         [cf_cv_define_sigwinch=maybe],
5791         [cf_cv_define_sigwinch=no])
5792 ])
5793 ])
5794
5795 if test "$cf_cv_define_sigwinch" = maybe ; then
5796 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
5797 cf_cv_fixup_sigwinch=unknown
5798 cf_sigwinch=32
5799 while test $cf_sigwinch != 1
5800 do
5801         AC_TRY_COMPILE([
5802 #undef _XOPEN_SOURCE
5803 #undef _POSIX_SOURCE
5804 #undef _POSIX_C_SOURCE
5805 #include <sys/types.h>
5806 #include <sys/signal.h>
5807 ],[
5808 #if SIGWINCH != $cf_sigwinch
5809 make an error
5810 #endif
5811 int x = SIGWINCH],
5812         [cf_cv_fixup_sigwinch=$cf_sigwinch
5813          break])
5814
5815 cf_sigwinch=`expr $cf_sigwinch - 1`
5816 done
5817 ])
5818
5819         if test "$cf_cv_fixup_sigwinch" != unknown ; then
5820                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
5821         fi
5822 fi
5823 ])dnl
5824 dnl ---------------------------------------------------------------------------
5825 dnl CF_SIG_ATOMIC_T version: 3 updated: 2012/10/04 20:12:20
5826 dnl ---------------
5827 dnl signal handler, but there are some gcc depedencies in that recommendation.
5828 dnl Try anyway.
5829 AC_DEFUN([CF_SIG_ATOMIC_T],
5830 [
5831 AC_MSG_CHECKING(for signal global datatype)
5832 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
5833         for cf_type in \
5834                 "volatile sig_atomic_t" \
5835                 "sig_atomic_t" \
5836                 "int"
5837         do
5838         AC_TRY_COMPILE([
5839 #include <sys/types.h>
5840 #include <signal.h>
5841 #include <stdio.h>
5842
5843 extern $cf_type x;
5844 $cf_type x;
5845 static void handler(int sig)
5846 {
5847         x = 5;
5848 }],
5849                 [signal(SIGINT, handler);
5850                  x = 1],
5851                 [cf_cv_sig_atomic_t=$cf_type],
5852                 [cf_cv_sig_atomic_t=no])
5853                 test "$cf_cv_sig_atomic_t" != no && break
5854         done
5855         ])
5856 AC_MSG_RESULT($cf_cv_sig_atomic_t)
5857 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
5858 ])dnl
5859 dnl ---------------------------------------------------------------------------
5860 dnl CF_SIZECHANGE version: 9 updated: 2012/10/06 11:17:15
5861 dnl -------------
5862 dnl Check for definitions & structures needed for window size-changing
5863 dnl FIXME: check that this works with "snake" (HP-UX 10.x)
5864 AC_DEFUN([CF_SIZECHANGE],
5865 [
5866 AC_REQUIRE([CF_STRUCT_TERMIOS])
5867 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
5868     cf_cv_sizechange=unknown
5869     cf_save_CPPFLAGS="$CPPFLAGS"
5870
5871 for cf_opts in "" "NEED_PTEM_H"
5872 do
5873
5874     CPPFLAGS="$cf_save_CPPFLAGS"
5875     test -n "$cf_opts" && CPPFLAGS="$CPPFLAGS -D$cf_opts"
5876     AC_TRY_COMPILE([#include <sys/types.h>
5877 #ifdef HAVE_TERMIOS_H
5878 #include <termios.h>
5879 #else
5880 #ifdef HAVE_TERMIO_H
5881 #include <termio.h>
5882 #endif
5883 #endif
5884 #ifdef NEED_PTEM_H
5885 /* This is a workaround for SCO:  they neglected to define struct winsize in
5886  * termios.h -- it's only in termio.h and ptem.h
5887  */
5888 #include        <sys/stream.h>
5889 #include        <sys/ptem.h>
5890 #endif
5891 #if !defined(sun) || !defined(HAVE_TERMIOS_H)
5892 #include <sys/ioctl.h>
5893 #endif
5894 ],[
5895 #ifdef TIOCGSIZE
5896         struct ttysize win;     /* FIXME: what system is this? */
5897         int y = win.ts_lines;
5898         int x = win.ts_cols;
5899 #else
5900 #ifdef TIOCGWINSZ
5901         struct winsize win;
5902         int y = win.ws_row;
5903         int x = win.ws_col;
5904 #else
5905         no TIOCGSIZE or TIOCGWINSZ
5906 #endif /* TIOCGWINSZ */
5907 #endif /* TIOCGSIZE */
5908         ],
5909         [cf_cv_sizechange=yes],
5910         [cf_cv_sizechange=no])
5911
5912         CPPFLAGS="$cf_save_CPPFLAGS"
5913         if test "$cf_cv_sizechange" = yes ; then
5914                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
5915                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
5916                 break
5917         fi
5918 done
5919 ])
5920 if test "$cf_cv_sizechange" != no ; then
5921         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechar declarations are provided])
5922         case $cf_cv_sizechange in #(vi
5923         NEED*)
5924                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
5925                 ;;
5926         esac
5927 fi
5928 ])dnl
5929 dnl ---------------------------------------------------------------------------
5930 dnl CF_SRC_MODULES version: 27 updated: 2013/08/03 18:18:08
5931 dnl --------------
5932 dnl For each parameter, test if the source-directory exists, and if it contains
5933 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
5934 dnl use in CF_LIB_RULES.
5935 dnl
5936 dnl This uses the configured value to make the lists SRC_SUBDIRS and
5937 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
5938 AC_DEFUN([CF_SRC_MODULES],
5939 [
5940 AC_MSG_CHECKING(for src modules)
5941
5942 # dependencies and linker-arguments for test-programs
5943 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
5944 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
5945 if test "$DFT_LWR_MODEL" = "libtool"; then
5946         TEST_ARGS="${TEST_DEPS}"
5947         TEST_ARG2="${TEST_DEP2}"
5948 else
5949         TEST_ARGS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
5950         TEST_ARG2="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARG2"
5951 fi
5952
5953 PC_MODULES_TO_MAKE="ncurses${DFT_ARG_SUFFIX}"
5954 cf_cv_src_modules=
5955 for cf_dir in $1
5956 do
5957         if test -f $srcdir/$cf_dir/modules; then
5958
5959                 # We may/may not have tack in the distribution, though the
5960                 # makefile is.
5961                 if test $cf_dir = tack ; then
5962                         if test ! -f $srcdir/${cf_dir}/${cf_dir}.h; then
5963                                 continue
5964                         fi
5965                 fi
5966
5967                 if test -z "$cf_cv_src_modules"; then
5968                         cf_cv_src_modules=$cf_dir
5969                 else
5970                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
5971                 fi
5972
5973                 # Make the ncurses_cfg.h file record the library interface files as
5974                 # well.  These are header files that are the same name as their
5975                 # directory.  Ncurses is the only library that does not follow
5976                 # that pattern.
5977                 if test $cf_dir = tack ; then
5978                         continue
5979                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
5980                         CF_UPPER(cf_have_include,$cf_dir)
5981                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
5982                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
5983                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
5984                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
5985                         if test "$DFT_LWR_MODEL" = "libtool"; then
5986                                 TEST_ARGS="${TEST_DEPS}"
5987                                 TEST_ARG2="${TEST_DEP2}"
5988                         else
5989                                 TEST_ARGS="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARGS"
5990                                 TEST_ARG2="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARG2"
5991                         fi
5992                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${DFT_ARG_SUFFIX}"
5993                 fi
5994         fi
5995 done
5996 AC_MSG_RESULT($cf_cv_src_modules)
5997
5998 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
5999 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
6000
6001 AC_SUBST(TEST_ARGS)
6002 AC_SUBST(TEST_DEPS)
6003
6004 AC_SUBST(TEST_ARG2)
6005 AC_SUBST(TEST_DEP2)
6006
6007 SRC_SUBDIRS=
6008 if test "x$cf_with_manpages" != xno ; then
6009         SRC_SUBDIRS="$SRC_SUBDIRS man"
6010 fi
6011 SRC_SUBDIRS="$SRC_SUBDIRS include"
6012 for cf_dir in $cf_cv_src_modules
6013 do
6014         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
6015 done
6016 if test "x$cf_with_tests" != "xno" ; then
6017         SRC_SUBDIRS="$SRC_SUBDIRS test"
6018 fi
6019 if test "x$cf_with_db_install" = xyes; then
6020         test -z "$MAKE_TERMINFO" && SRC_SUBDIRS="$SRC_SUBDIRS misc"
6021 fi
6022 if test "$cf_with_cxx_binding" != no; then
6023         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${DFT_ARG_SUFFIX}"
6024         SRC_SUBDIRS="$SRC_SUBDIRS c++"
6025 fi
6026
6027 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
6028 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
6029
6030 AC_SUBST(PC_MODULES_TO_MAKE)
6031
6032 ADA_SUBDIRS=
6033 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
6034         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
6035         ADA_SUBDIRS="gen src"
6036         if test "x$cf_with_tests" != "xno" ; then
6037                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
6038         fi
6039 fi
6040
6041 SUB_MAKEFILES=
6042 for cf_dir in $SRC_SUBDIRS
6043 do
6044         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
6045 done
6046
6047 if test -n "$ADA_SUBDIRS"; then
6048         for cf_dir in $ADA_SUBDIRS
6049         do
6050                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
6051         done
6052         AC_SUBST(ADA_SUBDIRS)
6053 fi
6054 ])dnl
6055 dnl ---------------------------------------------------------------------------
6056 dnl CF_STDCPP_LIBRARY version: 7 updated: 2010/05/29 16:31:02
6057 dnl -----------------
6058 dnl Check for -lstdc++, which is GNU's standard C++ library.
6059 AC_DEFUN([CF_STDCPP_LIBRARY],
6060 [
6061 if test -n "$GXX" ; then
6062 case $cf_cv_system_name in #(vi
6063 os2*) #(vi
6064         cf_stdcpp_libname=stdcpp
6065         ;;
6066 *)
6067         cf_stdcpp_libname=stdc++
6068         ;;
6069 esac
6070 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
6071         cf_save="$LIBS"
6072         CF_ADD_LIB($cf_stdcpp_libname)
6073 AC_TRY_LINK([
6074 #include <strstream.h>],[
6075 char buf[80];
6076 strstreambuf foo(buf, sizeof(buf))
6077 ],
6078         [cf_cv_libstdcpp=yes],
6079         [cf_cv_libstdcpp=no])
6080         LIBS="$cf_save"
6081 ])
6082 test "$cf_cv_libstdcpp" = yes && CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS)
6083 fi
6084 ])dnl
6085 dnl ---------------------------------------------------------------------------
6086 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
6087 dnl --------------
6088 dnl     Remove "-g" option from the compiler options
6089 AC_DEFUN([CF_STRIP_G_OPT],
6090 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
6091 dnl ---------------------------------------------------------------------------
6092 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
6093 dnl -------------------
6094 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
6095 dnl do this if we've found the sigaction function.
6096 AC_DEFUN([CF_STRUCT_SIGACTION],[
6097 AC_REQUIRE([CF_XOPEN_SOURCE])
6098
6099 if test "$ac_cv_func_sigaction" = yes; then
6100 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
6101 AC_TRY_COMPILE([
6102 #include <sys/types.h>
6103 #include <signal.h>],
6104         [struct sigaction act],
6105         [sigact_bad=no],
6106         [
6107 AC_TRY_COMPILE([
6108 #define _POSIX_SOURCE
6109 #include <sys/types.h>
6110 #include <signal.h>],
6111         [struct sigaction act],
6112         [sigact_bad=yes
6113          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
6114          [sigact_bad=unknown])])
6115 AC_MSG_RESULT($sigact_bad)
6116 fi
6117 ])dnl
6118 dnl ---------------------------------------------------------------------------
6119 dnl CF_STRUCT_TERMIOS version: 7 updated: 2012/10/06 17:56:13
6120 dnl -----------------
6121 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
6122 AC_DEFUN([CF_STRUCT_TERMIOS],[
6123 AC_REQUIRE([CF_XOPEN_SOURCE])
6124
6125 AC_CHECK_HEADERS( \
6126 termio.h \
6127 termios.h \
6128 unistd.h \
6129 )
6130
6131 if test "$ISC" = yes ; then
6132         AC_CHECK_HEADERS( sys/termio.h )
6133 fi
6134 if test "$ac_cv_header_termios_h" = yes ; then
6135         case "$CFLAGS $CPPFLAGS" in
6136         *-D_POSIX_SOURCE*)
6137                 termios_bad=dunno ;;
6138         *)      termios_bad=maybe ;;
6139         esac
6140         if test "$termios_bad" = maybe ; then
6141         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
6142         AC_TRY_COMPILE([#include <termios.h>],
6143                 [struct termios foo; int x = foo.c_iflag],
6144                 termios_bad=no, [
6145                 AC_TRY_COMPILE([
6146 #define _POSIX_SOURCE
6147 #include <termios.h>],
6148                         [struct termios foo; int x = foo.c_iflag],
6149                         termios_bad=unknown,
6150                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
6151                         ])
6152         AC_MSG_RESULT($termios_bad)
6153         fi
6154 fi
6155 ])dnl
6156 dnl ---------------------------------------------------------------------------
6157 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
6158 dnl --------------
6159 dnl Construct a search-list for a nonstandard header/lib-file
6160 dnl     $1 = the variable to return as result
6161 dnl     $2 = the package name
6162 dnl     $3 = the subdirectory, e.g., bin, include or lib
6163 AC_DEFUN([CF_SUBDIR_PATH],
6164 [
6165 $1=
6166
6167 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
6168 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
6169 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
6170 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
6171 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
6172 ])dnl
6173 dnl ---------------------------------------------------------------------------
6174 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
6175 dnl -----------
6176 dnl     Shorthand macro for substituting things that the user may override
6177 dnl     with an environment variable.
6178 dnl
6179 dnl     $1 = condition to pass to "test"
6180 dnl     $2 = environment variable
6181 dnl     $3 = value if the test succeeds
6182 dnl     $4 = value if the test fails
6183 AC_DEFUN([CF_SUBST_IF],
6184 [
6185 if test $1 ; then
6186         $2=$3
6187 ifelse($4,,,[else
6188         $2=$4])
6189 fi
6190 AC_SUBST($2)
6191 ])dnl
6192 dnl ---------------------------------------------------------------------------
6193 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
6194 dnl ------------------------
6195 dnl Get the version-number for use in shared-library naming, etc.
6196 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
6197 [
6198 AC_REQUIRE([CF_PROG_EGREP])
6199 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6200 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6201 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6202 cf_cv_abi_version=${NCURSES_MAJOR}
6203 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
6204 dnl Show the computed version, for logging
6205 cf_cv_timestamp=`date`
6206 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
6207 dnl We need these values in the generated headers
6208 AC_SUBST(NCURSES_MAJOR)
6209 AC_SUBST(NCURSES_MINOR)
6210 AC_SUBST(NCURSES_PATCH)
6211 dnl We need these values in the generated makefiles
6212 AC_SUBST(cf_cv_rel_version)
6213 AC_SUBST(cf_cv_abi_version)
6214 AC_SUBST(cf_cv_builtin_bool)
6215 AC_SUBST(cf_cv_header_stdbool_h)
6216 AC_SUBST(cf_cv_type_of_bool)dnl
6217 ])dnl
6218 dnl ---------------------------------------------------------------------------
6219 dnl CF_SYS_TIME_SELECT version: 5 updated: 2012/10/04 05:24:07
6220 dnl ------------------
6221 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
6222 dnl older SCO configurations.
6223 AC_DEFUN([CF_SYS_TIME_SELECT],
6224 [
6225 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
6226 AC_CACHE_VAL(cf_cv_sys_time_select,[
6227 AC_TRY_COMPILE([
6228 #include <sys/types.h>
6229 #ifdef HAVE_SYS_TIME_H
6230 #include <sys/time.h>
6231 #endif
6232 #ifdef HAVE_SYS_SELECT_H
6233 #include <sys/select.h>
6234 #endif
6235 ],[],[cf_cv_sys_time_select=yes],
6236      [cf_cv_sys_time_select=no])
6237      ])
6238 AC_MSG_RESULT($cf_cv_sys_time_select)
6239 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
6240 ])dnl
6241 dnl ---------------------------------------------------------------------------
6242 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
6243 dnl ---------------
6244 dnl Define a top_builddir symbol, for applications that need an absolute path.
6245 AC_DEFUN([CF_TOP_BUILDDIR],
6246 [
6247 top_builddir=ifelse($1,,`pwd`,$1)
6248 AC_SUBST(top_builddir)
6249 ])dnl
6250 dnl ---------------------------------------------------------------------------
6251 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
6252 dnl -------------------
6253 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
6254 dnl can define it successfully.
6255 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
6256 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
6257         AC_TRY_COMPILE([
6258 #include <stdlib.h>
6259 #include <string.h>
6260 #include <sys/types.h>
6261 ],[
6262 #ifndef _XOPEN_SOURCE
6263 make an error
6264 #endif],
6265         [cf_cv_xopen_source=no],
6266         [cf_save="$CPPFLAGS"
6267          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6268          AC_TRY_COMPILE([
6269 #include <stdlib.h>
6270 #include <string.h>
6271 #include <sys/types.h>
6272 ],[
6273 #ifdef _XOPEN_SOURCE
6274 make an error
6275 #endif],
6276         [cf_cv_xopen_source=no],
6277         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
6278         CPPFLAGS="$cf_save"
6279         ])
6280 ])
6281
6282 if test "$cf_cv_xopen_source" != no ; then
6283         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
6284         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
6285         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
6286         CF_ADD_CFLAGS($cf_temp_xopen_source)
6287 fi
6288 ])
6289 dnl ---------------------------------------------------------------------------
6290 dnl CF_TYPEOF_CHTYPE version: 9 updated: 2012/10/06 17:56:13
6291 dnl ----------------
6292 dnl Determine the type we should use for chtype (and attr_t, which is treated
6293 dnl as the same thing).  We want around 32 bits, so on most machines want a
6294 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
6295 dnl wide characters, we have to have a type compatible with that, as well.
6296 AC_DEFUN([CF_TYPEOF_CHTYPE],
6297 [
6298 AC_MSG_CHECKING([for type of chtype])
6299 AC_CACHE_VAL(cf_cv_typeof_chtype,[
6300                 AC_TRY_RUN([
6301 #define WANT_BITS 31
6302 #include <stdio.h>
6303 int main()
6304 {
6305         FILE *fp = fopen("cf_test.out", "w");
6306         if (fp != 0) {
6307                 char *result = "long";
6308                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
6309                         int n;
6310                         unsigned int x, y;
6311                         for (n = 0; n < WANT_BITS; n++) {
6312                                 x = (1 << n);
6313                                 y = (x >> n);
6314                                 if (y != 1 || x == 0) {
6315                                         x = 0;
6316                                         break;
6317                                 }
6318                         }
6319                         /*
6320                          * If x is nonzero, an int is big enough for the bits
6321                          * that we want.
6322                          */
6323                         result = (x != 0) ? "int" : "long";
6324                 }
6325                 fputs(result, fp);
6326                 fclose(fp);
6327         }
6328         ${cf_cv_main_return:-return}(0);
6329 }
6330                 ],
6331                 [cf_cv_typeof_chtype=`cat cf_test.out`],
6332                 [cf_cv_typeof_chtype=long],
6333                 [cf_cv_typeof_chtype=long])
6334                 rm -f cf_test.out
6335         ])
6336 AC_MSG_RESULT($cf_cv_typeof_chtype)
6337
6338 AC_SUBST(cf_cv_typeof_chtype)
6339 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
6340 ])dnl
6341 dnl ---------------------------------------------------------------------------
6342 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
6343 dnl -----------------
6344 dnl
6345 AC_DEFUN([CF_TYPE_SIGACTION],
6346 [
6347 AC_MSG_CHECKING([for type sigaction_t])
6348 AC_CACHE_VAL(cf_cv_type_sigaction,[
6349         AC_TRY_COMPILE([
6350 #include <signal.h>],
6351                 [sigaction_t x],
6352                 [cf_cv_type_sigaction=yes],
6353                 [cf_cv_type_sigaction=no])])
6354 AC_MSG_RESULT($cf_cv_type_sigaction)
6355 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
6356 ])dnl
6357 dnl ---------------------------------------------------------------------------
6358 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
6359 dnl --------------------
6360 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
6361 dnl won't, but they're still there.
6362 AC_DEFUN([CF_UNSIGNED_LITERALS],
6363 [
6364 AC_MSG_CHECKING([if unsigned literals are legal])
6365 AC_CACHE_VAL(cf_cv_unsigned_literals,[
6366         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
6367                 [cf_cv_unsigned_literals=yes],
6368                 [cf_cv_unsigned_literals=no])
6369         ])
6370 AC_MSG_RESULT($cf_cv_unsigned_literals)
6371 ])dnl
6372 dnl ---------------------------------------------------------------------------
6373 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
6374 dnl --------
6375 dnl Make an uppercase version of a variable
6376 dnl $1=uppercase($2)
6377 AC_DEFUN([CF_UPPER],
6378 [
6379 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6380 ])dnl
6381 dnl ---------------------------------------------------------------------------
6382 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
6383 dnl -----------
6384 dnl Check for multibyte support, and if not found, utf8 compatibility library
6385 AC_DEFUN([CF_UTF8_LIB],
6386 [
6387 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
6388         cf_save_LIBS="$LIBS"
6389         AC_TRY_LINK([
6390 #include <stdlib.h>],[putwc(0,0);],
6391         [cf_cv_utf8_lib=yes],
6392         [CF_FIND_LINKAGE([
6393 #include <libutf8.h>],[putwc(0,0);],utf8,
6394                 [cf_cv_utf8_lib=add-on],
6395                 [cf_cv_utf8_lib=no])
6396 ])])
6397
6398 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
6399 # ncurses/ncursesw:
6400 if test "$cf_cv_utf8_lib" = "add-on" ; then
6401         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
6402         CF_ADD_INCDIR($cf_cv_header_path_utf8)
6403         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
6404         CF_ADD_LIBS($cf_cv_library_file_utf8)
6405 fi
6406 ])dnl
6407 dnl ---------------------------------------------------------------------------
6408 dnl CF_VA_COPY version: 3 updated: 2012/10/06 11:17:15
6409 dnl ----------
6410 dnl check for va_copy, part of stdarg.h
6411 dnl Also, workaround for glibc's __va_copy, by checking for both.
6412 AC_DEFUN([CF_VA_COPY],[
6413 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
6414 AC_TRY_LINK([
6415 #include <stdarg.h>
6416 ],[
6417         static va_list dst;
6418         static va_list src;
6419         va_copy(dst, src)],
6420         cf_cv_have_va_copy=yes,
6421         cf_cv_have_va_copy=no)])
6422
6423 test "$cf_cv_have_va_copy" = yes && AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
6424
6425 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
6426 AC_TRY_LINK([
6427 #include <stdarg.h>
6428 ],[
6429         static va_list dst;
6430         static va_list src;
6431         __va_copy(dst, src)],
6432         cf_cv_have___va_copy=yes,
6433         cf_cv_have___va_copy=no)])
6434
6435 test "$cf_cv_have___va_copy" = yes && AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
6436 ])
6437 dnl ---------------------------------------------------------------------------
6438 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
6439 dnl ----------
6440 dnl Use AC_VERBOSE w/o the warnings
6441 AC_DEFUN([CF_VERBOSE],
6442 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
6443 CF_MSG_LOG([$1])
6444 ])dnl
6445 dnl ---------------------------------------------------------------------------
6446 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
6447 dnl -------------
6448 dnl Check if type wide-character type $1 is declared, and if so, which header
6449 dnl file is needed.  The second parameter is used to set a shell variable when
6450 dnl the type is not found.  The first parameter sets a shell variable for the
6451 dnl opposite sense.
6452 AC_DEFUN([CF_WCHAR_TYPE],
6453 [
6454 # This is needed on Tru64 5.0 to declare $1
6455 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
6456 AC_TRY_COMPILE([
6457 #include <stdlib.h>
6458 #include <stdarg.h>
6459 #include <stdio.h>
6460 #ifdef HAVE_LIBUTF8_H
6461 #include <libutf8.h>
6462 #endif],
6463         [$1 state],
6464         [cf_cv_$1=no],
6465         [AC_TRY_COMPILE([
6466 #include <stdlib.h>
6467 #include <stdarg.h>
6468 #include <stdio.h>
6469 #include <wchar.h>
6470 #ifdef HAVE_LIBUTF8_H
6471 #include <libutf8.h>
6472 #endif],
6473         [$1 value],
6474         [cf_cv_$1=yes],
6475         [cf_cv_$1=unknown])])])
6476
6477 if test "$cf_cv_$1" = yes ; then
6478         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
6479         NEED_WCHAR_H=1
6480 fi
6481
6482 ifelse([$2],,,[
6483 # if we do not find $1 in either place, use substitution to provide a fallback.
6484 if test "$cf_cv_$1" = unknown ; then
6485         $2=1
6486 fi
6487 ])
6488 ifelse($3,,,[
6489 # if we find $1 in either place, use substitution to provide a fallback.
6490 if test "$cf_cv_$1" != unknown ; then
6491         $3=1
6492 fi
6493 ])
6494 ])dnl
6495 dnl ---------------------------------------------------------------------------
6496 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
6497 dnl ---------------
6498 dnl Check for compiler-support for weak symbols.
6499 dnl This works with "recent" gcc.
6500 AC_DEFUN([CF_WEAK_SYMBOLS],[
6501 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
6502
6503 AC_TRY_COMPILE([
6504 #include <stdio.h>],
6505 [
6506 #if defined(__GNUC__)
6507 #  if defined __USE_ISOC99
6508 #    define _cat_pragma(exp)    _Pragma(#exp)
6509 #    define _weak_pragma(exp)   _cat_pragma(weak name)
6510 #  else
6511 #    define _weak_pragma(exp)
6512 #  endif
6513 #  define _declare(name)        __extension__ extern __typeof__(name) name
6514 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
6515 #endif
6516
6517 weak_symbol(fopen);
6518 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
6519 ])
6520 ])dnl
6521 dnl ---------------------------------------------------------------------------
6522 dnl CF_WITH_ABI_VERSION version: 1 updated: 2003/09/20 18:12:49
6523 dnl -------------------
6524 dnl Allow library's ABI to be overridden.  Generally this happens when a
6525 dnl packager has incremented the ABI past that used in the original package,
6526 dnl and wishes to keep doing this.
6527 dnl
6528 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
6529 dnl symbol.
6530 AC_DEFUN([CF_WITH_ABI_VERSION],[
6531 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
6532 AC_ARG_WITH(abi-version,
6533 [  --with-abi-version=XXX  override derived ABI version],
6534 [AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
6535  cf_cv_abi_version=$withval])
6536  CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
6537 ifelse($1,,,[
6538 $1_ABI=$cf_cv_abi_version
6539 ])
6540 ])dnl
6541 dnl ---------------------------------------------------------------------------
6542 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
6543 dnl --------------------
6544 dnl Command-line option to specify the Ada95 compiler.
6545 AC_DEFUN([CF_WITH_ADA_COMPILER],[
6546 AC_MSG_CHECKING(for ada-compiler)
6547 AC_ARG_WITH(ada-compiler,
6548         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
6549         [cf_ada_compiler=$withval],
6550         [cf_ada_compiler=gnatmake])
6551 AC_SUBST(cf_ada_compiler)
6552 AC_MSG_RESULT($cf_ada_compiler)
6553 ])dnl
6554 dnl ---------------------------------------------------------------------------
6555 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
6556 dnl -------------------
6557 dnl Command-line option to specify where Ada includes will install.
6558 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
6559 AC_MSG_CHECKING(for ada-include)
6560 CF_WITH_PATH(ada-include,
6561    [  --with-ada-include=DIR  Ada includes are in DIR],
6562    ADA_INCLUDE,
6563    PREFIX/share/ada/adainclude,
6564    [$]prefix/share/ada/adainclude)
6565 AC_SUBST(ADA_INCLUDE)
6566 AC_MSG_RESULT($ADA_INCLUDE)
6567 ])dnl
6568 dnl ---------------------------------------------------------------------------
6569 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
6570 dnl -------------------
6571 dnl Command-line option to specify where Ada objects will install.
6572 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
6573 AC_MSG_CHECKING(for ada-objects)
6574 CF_WITH_PATH(ada-objects,
6575    [  --with-ada-objects=DIR  Ada objects are in DIR],
6576    ADA_OBJECTS,
6577    PREFIX/lib/ada/adalib,
6578    [$]prefix/lib/ada/adalib)
6579 AC_SUBST(ADA_OBJECTS)
6580 AC_MSG_RESULT($ADA_OBJECTS)
6581 ])dnl
6582 dnl ---------------------------------------------------------------------------
6583 dnl CF_WITH_ADA_SHAREDLIB version: 3 updated: 2014/05/24 13:30:20
6584 dnl ---------------------
6585 dnl Command-line option to specify if an Ada95 shared-library should be built,
6586 dnl and optionally what its soname should be.
6587 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
6588 AC_REQUIRE([CF_GNAT_PROJECTS])
6589 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
6590 AC_ARG_WITH(ada-sharedlib,
6591         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
6592         [with_ada_sharedlib=$withval],
6593         [with_ada_sharedlib=no])
6594 AC_MSG_RESULT($with_ada_sharedlib)
6595
6596 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
6597 MAKE_ADA_SHAREDLIB="#"
6598
6599 if test "x$with_ada_sharedlib" != xno
6600 then
6601         if test "$cf_gnat_projects" != yes
6602         then
6603                 AC_MSG_ERROR(ada-sharedlib requires GNAT support for shared library projects,1)
6604         fi
6605         MAKE_ADA_SHAREDLIB=
6606         if test "x$with_ada_sharedlib" != xyes
6607         then
6608                 ADA_SHAREDLIB="$with_ada_sharedlib"
6609         fi
6610 fi
6611
6612 AC_SUBST(ADA_SHAREDLIB)
6613 AC_SUBST(MAKE_ADA_SHAREDLIB)
6614 ])dnl
6615 dnl ---------------------------------------------------------------------------
6616 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
6617 dnl ----------------
6618 dnl Configure-option for dbmalloc.  The optional parameter is used to override
6619 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6620 AC_DEFUN([CF_WITH_DBMALLOC],[
6621 CF_NO_LEAKS_OPTION(dbmalloc,
6622         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
6623         [USE_DBMALLOC])
6624
6625 if test "$with_dbmalloc" = yes ; then
6626         AC_CHECK_HEADER(dbmalloc.h,
6627                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
6628 fi
6629 ])dnl
6630 dnl ---------------------------------------------------------------------------
6631 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
6632 dnl ---------------
6633 dnl Configure-option for dmalloc.  The optional parameter is used to override
6634 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6635 AC_DEFUN([CF_WITH_DMALLOC],[
6636 CF_NO_LEAKS_OPTION(dmalloc,
6637         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
6638         [USE_DMALLOC])
6639
6640 if test "$with_dmalloc" = yes ; then
6641         AC_CHECK_HEADER(dmalloc.h,
6642                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
6643 fi
6644 ])dnl
6645 dnl ---------------------------------------------------------------------------
6646 dnl CF_WITH_GPM version: 8 updated: 2012/10/06 17:56:13
6647 dnl -----------
6648 dnl
6649 dnl The option parameter (if neither yes/no) is assumed to be the name of
6650 dnl the gpm library, e.g., for dynamic loading.
6651 AC_DEFUN([CF_WITH_GPM],
6652 [
6653 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
6654 AC_ARG_WITH(gpm,
6655         [  --with-gpm              use Alessandro Rubini's GPM library],
6656         [with_gpm=$withval],
6657         [with_gpm=maybe])
6658 AC_MSG_RESULT($with_gpm)
6659
6660 if test "$with_gpm" != no ; then
6661         AC_CHECK_HEADER(gpm.h,[
6662                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
6663                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
6664                         CF_VERBOSE(assuming we really have GPM library)
6665                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
6666                 else
6667                         AC_CHECK_LIB(gpm,Gpm_Open,[:],[
6668                                 AC_MSG_ERROR(Cannot link with GPM library)
6669                 fi
6670                 with_gpm=yes
6671                 ])
6672         ],[
6673                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
6674                 with_gpm=no
6675         ])
6676 fi
6677 ])
6678 dnl ---------------------------------------------------------------------------
6679 dnl CF_WITH_LIBTOOL version: 30 updated: 2013/09/07 13:54:05
6680 dnl ---------------
6681 dnl Provide a configure option to incorporate libtool.  Define several useful
6682 dnl symbols for the makefile rules.
6683 dnl
6684 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
6685 dnl macros from libtool.m4 which is in the aclocal directory of automake.
6686 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
6687 dnl But that still does not work properly since the macro is expanded outside
6688 dnl the CF_WITH_LIBTOOL macro:
6689 dnl
6690 dnl     #!/bin/sh
6691 dnl     ACLOCAL=`aclocal --print-ac-dir`
6692 dnl     if test -z "$ACLOCAL" ; then
6693 dnl             echo cannot find aclocal directory
6694 dnl             exit 1
6695 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
6696 dnl             echo cannot find libtool.m4 file
6697 dnl             exit 1
6698 dnl     fi
6699 dnl
6700 dnl     LOCAL=aclocal.m4
6701 dnl     ORIG=aclocal.m4.orig
6702 dnl
6703 dnl     trap "mv $ORIG $LOCAL" 0 1 2 5 15
6704 dnl     rm -f $ORIG
6705 dnl     mv $LOCAL $ORIG
6706 dnl
6707 dnl     # sed the LIBTOOL= assignment to omit the current directory?
6708 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
6709 dnl     cat $ORIG >>$LOCAL
6710 dnl
6711 dnl     autoconf-257 $*
6712 dnl
6713 AC_DEFUN([CF_WITH_LIBTOOL],
6714 [
6715 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
6716 ifdef([AC_PROG_LIBTOOL],,[
6717 LIBTOOL=
6718 ])
6719 # common library maintenance symbols that are convenient for libtool scripts:
6720 LIB_CREATE='${AR} -cr'
6721 LIB_OBJECT='${OBJECTS}'
6722 LIB_SUFFIX=.a
6723 LIB_PREP="$RANLIB"
6724
6725 # symbols used to prop libtool up to enable it to determine what it should be
6726 # doing:
6727 LIB_CLEAN=
6728 LIB_COMPILE=
6729 LIB_LINK='${CC}'
6730 LIB_INSTALL=
6731 LIB_UNINSTALL=
6732
6733 AC_MSG_CHECKING(if you want to build libraries with libtool)
6734 AC_ARG_WITH(libtool,
6735         [  --with-libtool          generate libraries with libtool],
6736         [with_libtool=$withval],
6737         [with_libtool=no])
6738 AC_MSG_RESULT($with_libtool)
6739 if test "$with_libtool" != "no"; then
6740 ifdef([AC_PROG_LIBTOOL],[
6741         # missing_content_AC_PROG_LIBTOOL{{
6742         AC_PROG_LIBTOOL
6743         # missing_content_AC_PROG_LIBTOOL}}
6744 ],[
6745         if test "$with_libtool" != "yes" ; then
6746                 CF_PATH_SYNTAX(with_libtool)
6747                 LIBTOOL=$with_libtool
6748         else
6749                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
6750                 CF_LIBTOOL_VERSION
6751                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
6752                 then
6753                         CF_FORGET_TOOL(LIBTOOL)
6754                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
6755                         CF_LIBTOOL_VERSION
6756                 fi
6757         fi
6758         if test -z "$LIBTOOL" ; then
6759                 AC_MSG_ERROR(Cannot find libtool)
6760         fi
6761 ])dnl
6762         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${DESTDIR}${libdir} ${LIBTOOL_VERSION} `cut -f1 ${srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
6763         LIB_OBJECT='${OBJECTS:.o=.lo}'
6764         LIB_SUFFIX=.la
6765         LIB_CLEAN='${LIBTOOL} --mode=clean'
6766         LIB_COMPILE='${LIBTOOL} --mode=compile'
6767         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
6768         LIB_INSTALL='${LIBTOOL} --mode=install'
6769         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
6770         LIB_PREP=:
6771
6772         CF_CHECK_LIBTOOL_VERSION
6773
6774         # special hack to add -no-undefined (which libtool should do for itself)
6775         LT_UNDEF=
6776         case "$cf_cv_system_name" in #(vi
6777         cygwin*|msys*|mingw32*|uwin*|aix[[4-7]]) #(vi
6778                 LT_UNDEF=-no-undefined
6779                 ;;
6780         esac
6781         AC_SUBST([LT_UNDEF])
6782
6783         # special hack to add --tag option for C++ compiler
6784         case $cf_cv_libtool_version in #(vi
6785         1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*) #(vi
6786                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
6787                 LIBTOOL="$LIBTOOL --tag=CC"
6788                 ;;
6789         *)
6790                 LIBTOOL_CXX="$LIBTOOL"
6791                 ;;
6792         esac
6793 else
6794         LIBTOOL=""
6795         LIBTOOL_CXX=""
6796 fi
6797
6798 test -z "$LIBTOOL" && ECHO_LT=
6799
6800 AC_SUBST(LIBTOOL)
6801 AC_SUBST(LIBTOOL_CXX)
6802 AC_SUBST(LIBTOOL_OPTS)
6803
6804 AC_SUBST(LIB_CREATE)
6805 AC_SUBST(LIB_OBJECT)
6806 AC_SUBST(LIB_SUFFIX)
6807 AC_SUBST(LIB_PREP)
6808
6809 AC_SUBST(LIB_CLEAN)
6810 AC_SUBST(LIB_COMPILE)
6811 AC_SUBST(LIB_LINK)
6812 AC_SUBST(LIB_INSTALL)
6813 AC_SUBST(LIB_UNINSTALL)
6814
6815 ])dnl
6816 dnl ---------------------------------------------------------------------------
6817 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
6818 dnl ------------------
6819 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
6820 dnl "lib" prefix, e.g., because it used the dll naming convention.
6821 dnl
6822 dnl $1 = variable to set
6823 AC_DEFUN([CF_WITH_LIB_PREFIX],
6824 [
6825 AC_MSG_CHECKING(if you want to have a library-prefix)
6826 AC_ARG_WITH(lib-prefix,
6827         [  --with-lib-prefix       override library-prefix],
6828         [with_lib_prefix=$withval],
6829         [with_lib_prefix=auto])
6830 AC_MSG_RESULT($with_lib_prefix)
6831
6832 if test $with_lib_prefix = auto
6833 then
6834         CF_LIB_PREFIX($1)
6835 elif test $with_lib_prefix = no
6836 then
6837         LIB_PREFIX=
6838 else
6839         LIB_PREFIX=$with_lib_prefix
6840 fi
6841 ])dnl
6842 dnl ---------------------------------------------------------------------------
6843 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
6844 dnl ------------
6845 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
6846 dnl defaulting to yes/no.
6847 dnl
6848 dnl $1 = option name
6849 dnl $2 = help-text
6850 dnl $3 = environment variable to set
6851 dnl $4 = default value, shown in the help-message, must be a constant
6852 dnl $5 = default value, if it's an expression & cannot be in the help-message
6853 dnl
6854 AC_DEFUN([CF_WITH_PATH],
6855 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
6856 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
6857 if ifelse([$5],,true,[test -n "$5"]) ; then
6858 CF_PATH_SYNTAX(withval)
6859 fi
6860 eval $3="$withval"
6861 AC_SUBST($3)dnl
6862 ])dnl
6863 dnl ---------------------------------------------------------------------------
6864 dnl CF_WITH_PATHLIST version: 9 updated: 2012/10/18 05:05:24
6865 dnl ----------------
6866 dnl Process an option specifying a list of colon-separated paths.
6867 dnl
6868 dnl $1 = option name
6869 dnl $2 = help-text
6870 dnl $3 = environment variable to set
6871 dnl $4 = default value, shown in the help-message, must be a constant
6872 dnl $5 = default value, if it's an expression & cannot be in the help-message
6873 dnl $6 = flag to tell if we want to define or substitute
6874 dnl
6875 AC_DEFUN([CF_WITH_PATHLIST],[
6876 AC_REQUIRE([CF_PATHSEP])
6877 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
6878 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
6879
6880 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
6881 cf_dst_path=
6882 for cf_src_path in $withval
6883 do
6884   CF_PATH_SYNTAX(cf_src_path)
6885   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
6886   cf_dst_path="${cf_dst_path}${cf_src_path}"
6887 done
6888 IFS="$ac_save_ifs"
6889
6890 ifelse($6,define,[
6891 # Strip single quotes from the value, e.g., when it was supplied as a literal
6892 # for $4 or $5.
6893 case $cf_dst_path in #(vi
6894 \'*)
6895   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
6896   ;;
6897 esac
6898 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
6899 ])
6900
6901 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
6902 # so we have to check/work around.  We do prefer the result of "eval"...
6903 eval cf_dst_eval="$cf_dst_path"
6904 case "x$cf_dst_eval" in #(vi
6905 xNONE*) #(vi
6906         $3=$cf_dst_path
6907         ;;
6908 *)
6909         $3="$cf_dst_eval"
6910         ;;
6911 esac
6912 AC_SUBST($3)dnl
6913
6914 ])dnl
6915 dnl ---------------------------------------------------------------------------
6916 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 2 updated: 2011/12/10 18:58:47
6917 dnl -------------------------
6918 dnl Allow the choice of the pkg-config library directory to be overridden.
6919 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
6920 if test "$PKG_CONFIG" != none ; then
6921         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
6922         AC_ARG_WITH(pkg-config-libdir,
6923                 [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
6924                 [PKG_CONFIG_LIBDIR=$withval],
6925                 [PKG_CONFIG_LIBDIR=yes])
6926
6927         case x$PKG_CONFIG_LIBDIR in #(vi
6928         x/*) #(vi
6929                 ;;
6930         xyes) #(vi
6931                 # look for the library directory using the same prefix as the executable
6932                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
6933                 case x`(arch) 2>/dev/null` in #(vi
6934                 *64) #(vi
6935                         for cf_config in $cf_path/share $cf_path/lib64 $cf_path/lib32 $cf_path/lib
6936                         do
6937                                 if test -d $cf_config/pkgconfig
6938                                 then
6939                                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
6940                                         break
6941                                 fi
6942                         done
6943                         ;;
6944                 *)
6945                         PKG_CONFIG_LIBDIR=$cf_path/lib/pkgconfig
6946                         ;;
6947                 esac
6948                 ;;
6949         *)
6950                 ;;
6951         esac
6952
6953         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
6954 fi
6955
6956 AC_SUBST(PKG_CONFIG_LIBDIR)
6957 ])dnl
6958 dnl ---------------------------------------------------------------------------
6959 dnl CF_WITH_PTHREAD version: 6 updated: 2012/10/06 17:41:51
6960 dnl ---------------
6961 dnl Check for POSIX thread library.
6962 AC_DEFUN([CF_WITH_PTHREAD],
6963 [
6964 AC_MSG_CHECKING(if you want to link with the pthread library)
6965 AC_ARG_WITH(pthread,
6966     [  --with-pthread          use POSIX thread library],
6967     [with_pthread=$withval],
6968     [with_pthread=no])
6969 AC_MSG_RESULT($with_pthread)
6970
6971 if test "$with_pthread" != no ; then
6972     AC_CHECK_HEADER(pthread.h,[
6973         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
6974
6975         for cf_lib_pthread in pthread c_r
6976         do
6977             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
6978             cf_save_LIBS="$LIBS"
6979             CF_ADD_LIB($cf_lib_pthread)
6980             AC_TRY_LINK([
6981 #include <pthread.h>
6982 ],[
6983                 int rc = pthread_create(0,0,0,0);
6984                 int r2 = pthread_mutexattr_settype(0, 0);
6985 ],[with_pthread=yes],[with_pthread=no])
6986             LIBS="$cf_save_LIBS"
6987             AC_MSG_RESULT($with_pthread)
6988             test "$with_pthread" = yes && break
6989         done
6990
6991         if test "$with_pthread" = yes ; then
6992             CF_ADD_LIB($cf_lib_pthread)
6993             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
6994         else
6995             AC_MSG_ERROR(Cannot link with pthread library)
6996         fi
6997     ])
6998 fi
6999 ])
7000 dnl ---------------------------------------------------------------------------
7001 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
7002 dnl -------------------
7003 dnl Allow library's release-version to be overridden.  Generally this happens when a
7004 dnl packager has incremented the release-version past that used in the original package,
7005 dnl and wishes to keep doing this.
7006 dnl
7007 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
7008 dnl and {package}_MINOR symbols
7009 dnl symbol.
7010 AC_DEFUN([CF_WITH_REL_VERSION],[
7011 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
7012 AC_ARG_WITH(rel-version,
7013 [  --with-rel-version=XXX  override derived release version],
7014 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
7015  cf_cv_rel_version=$withval])
7016 ifelse($1,,[
7017  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
7018 ],[
7019  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
7020  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
7021  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
7022  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
7023 ])
7024 ])dnl
7025 dnl ---------------------------------------------------------------------------
7026 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
7027 dnl ----------------
7028 dnl If we can compile with sysmouse, make it available unless it is not wanted.
7029 AC_DEFUN([CF_WITH_SYSMOUSE],[
7030 # not everyone has "test -c"
7031 if test -c /dev/sysmouse 2>/dev/null ; then
7032 AC_MSG_CHECKING(if you want to use sysmouse)
7033 AC_ARG_WITH(sysmouse,
7034         [  --with-sysmouse         use sysmouse (FreeBSD console)],
7035         [cf_with_sysmouse=$withval],
7036         [cf_with_sysmouse=maybe])
7037         if test "$cf_with_sysmouse" != no ; then
7038         AC_TRY_COMPILE([
7039 #include <osreldate.h>
7040 #if (__FreeBSD_version >= 400017)
7041 #include <sys/consio.h>
7042 #include <sys/fbio.h>
7043 #else
7044 #include <machine/console.h>
7045 #endif
7046 ],[
7047         struct mouse_info the_mouse;
7048         ioctl(0, CONS_MOUSECTL, &the_mouse);
7049 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
7050         fi
7051 AC_MSG_RESULT($cf_with_sysmouse)
7052 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
7053 fi
7054 ])dnl
7055 dnl ---------------------------------------------------------------------------
7056 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
7057 dnl ---------------
7058 dnl For testing, override the derived host system-type which is used to decide
7059 dnl things such as the linker commands used to build shared libraries.  This is
7060 dnl normally chosen automatically based on the type of system which you are
7061 dnl building on.  We use it for testing the configure script.
7062 dnl
7063 dnl This is different from the --host option: it is used only for testing parts
7064 dnl of the configure script which would not be reachable with --host since that
7065 dnl relies on the build environment being real, rather than mocked up.
7066 AC_DEFUN([CF_WITH_SYSTYPE],[
7067 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
7068 AC_ARG_WITH(system-type,
7069         [  --with-system-type=XXX  test: override derived host system-type],
7070 [AC_MSG_WARN(overriding system type to $withval)
7071         cf_cv_system_name=$withval
7072         host_os=$withval
7073 ])
7074 ])dnl
7075 dnl ---------------------------------------------------------------------------
7076 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
7077 dnl ----------------
7078 AC_DEFUN([CF_WITH_VALGRIND],[
7079 CF_NO_LEAKS_OPTION(valgrind,
7080         [  --with-valgrind         test: use valgrind],
7081         [USE_VALGRIND])
7082 ])dnl
7083 dnl ---------------------------------------------------------------------------
7084 dnl CF_XOPEN_SOURCE version: 46 updated: 2014/02/09 19:30:15
7085 dnl ---------------
7086 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
7087 dnl or adapt to the vendor's definitions to get equivalent functionality,
7088 dnl without losing the common non-POSIX features.
7089 dnl
7090 dnl Parameters:
7091 dnl     $1 is the nominal value for _XOPEN_SOURCE
7092 dnl     $2 is the nominal value for _POSIX_C_SOURCE
7093 AC_DEFUN([CF_XOPEN_SOURCE],[
7094 AC_REQUIRE([AC_CANONICAL_HOST])
7095
7096 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
7097 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
7098 cf_xopen_source=
7099
7100 case $host_os in #(vi
7101 aix[[4-7]]*) #(vi
7102         cf_xopen_source="-D_ALL_SOURCE"
7103         ;;
7104 cygwin|msys) #(vi
7105         cf_XOPEN_SOURCE=600
7106         ;;
7107 darwin[[0-8]].*) #(vi
7108         cf_xopen_source="-D_APPLE_C_SOURCE"
7109         ;;
7110 darwin*) #(vi
7111         cf_xopen_source="-D_DARWIN_C_SOURCE"
7112         cf_XOPEN_SOURCE=
7113         ;;
7114 freebsd*|dragonfly*) #(vi
7115         # 5.x headers associate
7116         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
7117         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
7118         cf_POSIX_C_SOURCE=200112L
7119         cf_XOPEN_SOURCE=600
7120         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
7121         ;;
7122 hpux11*) #(vi
7123         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
7124         ;;
7125 hpux*) #(vi
7126         cf_xopen_source="-D_HPUX_SOURCE"
7127         ;;
7128 irix[[56]].*) #(vi
7129         cf_xopen_source="-D_SGI_SOURCE"
7130         cf_XOPEN_SOURCE=
7131         ;;
7132 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
7133         CF_GNU_SOURCE
7134         ;;
7135 mirbsd*) #(vi
7136         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
7137         cf_XOPEN_SOURCE=
7138         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7139         ;;
7140 netbsd*) #(vi
7141         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
7142         ;;
7143 openbsd[[4-9]]*) #(vi
7144         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
7145         cf_xopen_source="-D_BSD_SOURCE"
7146         cf_XOPEN_SOURCE=600
7147         ;;
7148 openbsd*) #(vi
7149         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
7150         ;;
7151 osf[[45]]*) #(vi
7152         cf_xopen_source="-D_OSF_SOURCE"
7153         ;;
7154 nto-qnx*) #(vi
7155         cf_xopen_source="-D_QNX_SOURCE"
7156         ;;
7157 sco*) #(vi
7158         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
7159         ;;
7160 solaris2.*) #(vi
7161         cf_xopen_source="-D__EXTENSIONS__"
7162         cf_cv_xopen_source=broken
7163         ;;
7164 *)
7165         CF_TRY_XOPEN_SOURCE
7166         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7167         ;;
7168 esac
7169
7170 if test -n "$cf_xopen_source" ; then
7171         CF_ADD_CFLAGS($cf_xopen_source)
7172 fi
7173
7174 dnl In anything but the default case, we may have system-specific setting
7175 dnl which is still not guaranteed to provide all of the entrypoints that
7176 dnl _XOPEN_SOURCE would yield.
7177 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
7178         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
7179         AC_TRY_COMPILE([#include <stdlib.h>],[
7180 #ifndef _XOPEN_SOURCE
7181 make an error
7182 #endif],
7183         [cf_XOPEN_SOURCE_set=yes],
7184         [cf_XOPEN_SOURCE_set=no])
7185         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
7186         if test $cf_XOPEN_SOURCE_set = yes
7187         then
7188                 AC_TRY_COMPILE([#include <stdlib.h>],[
7189 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
7190 make an error
7191 #endif],
7192                 [cf_XOPEN_SOURCE_set_ok=yes],
7193                 [cf_XOPEN_SOURCE_set_ok=no])
7194                 if test $cf_XOPEN_SOURCE_set_ok = no
7195                 then
7196                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
7197                 fi
7198         else
7199                 CF_TRY_XOPEN_SOURCE
7200         fi
7201 fi
7202 ])