aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2011,2012 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.622 2012/08/26 14:01:23 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 3 updated: 2002/10/27 23:21:42
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54     [AC_TRY_LINK([#include <langinfo.h>],
  55       [char* cs = nl_langinfo(CODESET);],
  56       am_cv_langinfo_codeset=yes,
  57       am_cv_langinfo_codeset=no)
  58     ])
  59   if test $am_cv_langinfo_codeset = yes; then
  60     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62   fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ACVERSION_CHECK version: 2 updated: 2011/05/08 11:22:03
  66 dnl ------------------
  67 dnl Conditionally generate script according to whether we're using a given autoconf.
  68 dnl
  69 dnl $1 = version to compare against
  70 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  71 dnl $3 = code to use if AC_ACVERSION is older than $1.
  72 define(CF_ACVERSION_CHECK,
  73 [
  74 ifdef([m4_version_compare],
  75 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  76 [CF_ACVERSION_COMPARE(
  77 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  78 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  79 dnl ---------------------------------------------------------------------------
  80 dnl CF_ACVERSION_COMPARE version: 2 updated: 2011/04/14 20:56:50
  81 dnl --------------------
  82 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  83 dnl                      MAJOR2, MINOR2, TERNARY2,
  84 dnl                      PRINTABLE2, not FOUND, FOUND)
  85 define(CF_ACVERSION_COMPARE,
  86 [ifelse(builtin([eval], [$2 < $5]), 1,
  87 [ifelse([$8], , ,[$8])],
  88 [ifelse([$9], , ,[$9])])])dnl
  89 dnl ---------------------------------------------------------------------------
  90 dnl CF_ADA_INCLUDE_DIRS version: 6 updated: 2010/02/26 19:52:07
  91 dnl -------------------
  92 dnl Construct the list of include-options for the C programs in the Ada95
  93 dnl binding.
  94 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  95 [
  96 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  97 if test "$srcdir" != "."; then
  98         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  99 fi
 100 if test "$GCC" != yes; then
 101         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 102 elif test "$includedir" != "/usr/include"; then
 103         if test "$includedir" = '${prefix}/include' ; then
 104                 if test $prefix != /usr ; then
 105                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 106                 fi
 107         else
 108                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 109         fi
 110 fi
 111 AC_SUBST(ACPPFLAGS)
 112 ])dnl
 113 dnl ---------------------------------------------------------------------------
 114 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 115 dnl ---------------
 116 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 117 AC_DEFUN([CF_ADD_ADAFLAGS],[
 118         ADAFLAGS="$ADAFLAGS $1"
 119         AC_SUBST(ADAFLAGS)
 120 ])dnl
 121 dnl ---------------------------------------------------------------------------
 122 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
 123 dnl -------------
 124 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 125 dnl The second parameter if given makes this macro verbose.
 126 dnl
 127 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 128 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 129 dnl confused by the quotes (which require backslashes to keep them usable).
 130 AC_DEFUN([CF_ADD_CFLAGS],
 131 [
 132 cf_fix_cppflags=no
 133 cf_new_cflags=
 134 cf_new_cppflags=
 135 cf_new_extra_cppflags=
 136
 137 for cf_add_cflags in $1
 138 do
 139 case $cf_fix_cppflags in
 140 no)
 141         case $cf_add_cflags in #(vi
 142         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
 143                 case $cf_add_cflags in
 144                 -D*)
 145                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 146
 147                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 148                                 && test -z "${cf_tst_cflags}" \
 149                                 && cf_fix_cppflags=yes
 150
 151                         if test $cf_fix_cppflags = yes ; then
 152                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 153                                 continue
 154                         elif test "${cf_tst_cflags}" = "\"'" ; then
 155                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 156                                 continue
 157                         fi
 158                         ;;
 159                 esac
 160                 case "$CPPFLAGS" in
 161                 *$cf_add_cflags) #(vi
 162                         ;;
 163                 *) #(vi
 164                         case $cf_add_cflags in #(vi
 165                         -D*)
 166                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 167                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 168                                 ;;
 169                         esac
 170                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 171                         ;;
 172                 esac
 173                 ;;
 174         *)
 175                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 176                 ;;
 177         esac
 178         ;;
 179 yes)
 180         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 181
 182         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 183
 184         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 185                 && test -z "${cf_tst_cflags}" \
 186                 && cf_fix_cppflags=no
 187         ;;
 188 esac
 189 done
 190
 191 if test -n "$cf_new_cflags" ; then
 192         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 193         CFLAGS="$CFLAGS $cf_new_cflags"
 194 fi
 195
 196 if test -n "$cf_new_cppflags" ; then
 197         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 198         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 199 fi
 200
 201 if test -n "$cf_new_extra_cppflags" ; then
 202         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 203         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 204 fi
 205
 206 AC_SUBST(EXTRA_CPPFLAGS)
 207
 208 ])dnl
 209 dnl ---------------------------------------------------------------------------
 210 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 211 dnl -------------
 212 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 213 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 214 dnl but old versions (and some misinstalled ones) need that.  To make things
 215 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 216 dnl the include-path).
 217 AC_DEFUN([CF_ADD_INCDIR],
 218 [
 219 if test -n "$1" ; then
 220   for cf_add_incdir in $1
 221   do
 222         while test $cf_add_incdir != /usr/include
 223         do
 224           if test -d $cf_add_incdir
 225           then
 226                 cf_have_incdir=no
 227                 if test -n "$CFLAGS$CPPFLAGS" ; then
 228                   # a loop is needed to ensure we can add subdirs of existing dirs
 229                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 230                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 231                           cf_have_incdir=yes; break
 232                         fi
 233                   done
 234                 fi
 235
 236                 if test "$cf_have_incdir" = no ; then
 237                   if test "$cf_add_incdir" = /usr/local/include ; then
 238                         if test "$GCC" = yes
 239                         then
 240                           cf_save_CPPFLAGS=$CPPFLAGS
 241                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 242                           AC_TRY_COMPILE([#include <stdio.h>],
 243                                   [printf("Hello")],
 244                                   [],
 245                                   [cf_have_incdir=yes])
 246                           CPPFLAGS=$cf_save_CPPFLAGS
 247                         fi
 248                   fi
 249                 fi
 250
 251                 if test "$cf_have_incdir" = no ; then
 252                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 253                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 254
 255                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 256                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 257                   cf_add_incdir="$cf_top_incdir"
 258                 else
 259                   break
 260                 fi
 261           fi
 262         done
 263   done
 264 fi
 265 ])dnl
 266 dnl ---------------------------------------------------------------------------
 267 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 268 dnl ----------
 269 dnl Add a library, used to enforce consistency.
 270 dnl
 271 dnl $1 = library to add, without the "-l"
 272 dnl $2 = variable to update (default $LIBS)
 273 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 274 dnl ---------------------------------------------------------------------------
 275 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 276 dnl -------------
 277 dnl     Adds to the library-path
 278 dnl
 279 dnl     Some machines have trouble with multiple -L options.
 280 dnl
 281 dnl $1 is the (list of) directory(s) to add
 282 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 283 dnl
 284 AC_DEFUN([CF_ADD_LIBDIR],
 285 [
 286 if test -n "$1" ; then
 287   for cf_add_libdir in $1
 288   do
 289     if test $cf_add_libdir = /usr/lib ; then
 290       :
 291     elif test -d $cf_add_libdir
 292     then
 293       cf_have_libdir=no
 294       if test -n "$LDFLAGS$LIBS" ; then
 295         # a loop is needed to ensure we can add subdirs of existing dirs
 296         for cf_test_libdir in $LDFLAGS $LIBS ; do
 297           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 298             cf_have_libdir=yes; break
 299           fi
 300         done
 301       fi
 302       if test "$cf_have_libdir" = no ; then
 303         CF_VERBOSE(adding $cf_add_libdir to library-path)
 304         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 305       fi
 306     fi
 307   done
 308 fi
 309 ])dnl
 310 dnl ---------------------------------------------------------------------------
 311 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 312 dnl -----------
 313 dnl Add one or more libraries, used to enforce consistency.
 314 dnl
 315 dnl $1 = libraries to add, with the "-l", etc.
 316 dnl $2 = variable to update (default $LIBS)
 317 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 318 dnl ---------------------------------------------------------------------------
 319 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
 320 dnl ------------------
 321 dnl Append to a search-list for a nonstandard header/lib-file
 322 dnl     $1 = the variable to return as result
 323 dnl     $2 = the package name
 324 dnl     $3 = the subdirectory, e.g., bin, include or lib
 325 dnl $4 = the directory under which we will test for subdirectories
 326 dnl $5 = a directory that we do not want $4 to match
 327 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 328 [
 329 test "$4" != "$5" && \
 330 test -d "$4" && \
 331 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
 332         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 333         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 334         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 335         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 336         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 337         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 338 }
 339 ])dnl
 340 dnl ---------------------------------------------------------------------------
 341 dnl CF_ANSI_CC_CHECK version: 11 updated: 2011/07/01 19:47:45
 342 dnl ----------------
 343 dnl This was originally adapted from the macros 'fp_PROG_CC_STDC' and
 344 dnl 'fp_C_PROTOTYPES' in the sharutils 4.2 distribution.
 345 AC_DEFUN([CF_ANSI_CC_CHECK],
 346 [
 347 # This should have been defined by AC_PROG_CC
 348 : ${CC:=cc}
 349
 350 # Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 351 # into CC.  This will not help with broken scripts that wrap the compiler with
 352 # options, but eliminates a more common category of user confusion.
 353 AC_MSG_CHECKING(\$CC variable)
 354 case "$CC" in #(vi
 355 *[[\ \  ]]-[[IUD]]*)
 356         AC_MSG_RESULT(broken)
 357         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 358         # humor him...
 359         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 360         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 361         CF_ADD_CFLAGS($cf_flags)
 362         ;;
 363 *)
 364         AC_MSG_RESULT(ok)
 365         ;;
 366 esac
 367
 368 AC_CACHE_CHECK(for ${CC:-cc} option to accept ANSI C, cf_cv_ansi_cc,[
 369 cf_cv_ansi_cc=no
 370 cf_save_CFLAGS="$CFLAGS"
 371 cf_save_CPPFLAGS="$CPPFLAGS"
 372 # Don't try gcc -ansi; that turns off useful extensions and
 373 # breaks some systems' header files.
 374 # AIX                   -qlanglvl=ansi
 375 # Ultrix and OSF/1      -std1
 376 # HP-UX                 -Aa -D_HPUX_SOURCE
 377 # SVR4                  -Xc
 378 # UnixWare 1.2          (cannot use -Xc, since ANSI/POSIX clashes)
 379 for cf_arg in "-DCC_HAS_PROTOS" \
 380         "" \
 381         -qlanglvl=ansi \
 382         -std1 \
 383         -Ae \
 384         "-Aa -D_HPUX_SOURCE" \
 385         -Xc
 386 do
 387         CF_ADD_CFLAGS($cf_arg)
 388         AC_TRY_COMPILE(
 389 [
 390 #ifndef CC_HAS_PROTOS
 391 #if !defined(__STDC__) || (__STDC__ != 1)
 392 choke me
 393 #endif
 394 #endif
 395 ],[
 396         int test (int i, double x);
 397         struct s1 {int (*f) (int a);};
 398         struct s2 {int (*f) (double a);};],
 399         [cf_cv_ansi_cc="$cf_arg"; break])
 400 done
 401 CFLAGS="$cf_save_CFLAGS"
 402 CPPFLAGS="$cf_save_CPPFLAGS"
 403 ])
 404
 405 if test "$cf_cv_ansi_cc" != "no"; then
 406 if test ".$cf_cv_ansi_cc" != ".-DCC_HAS_PROTOS"; then
 407         CF_ADD_CFLAGS($cf_cv_ansi_cc)
 408 else
 409         AC_DEFINE(CC_HAS_PROTOS)
 410 fi
 411 fi
 412 ])dnl
 413 dnl ---------------------------------------------------------------------------
 414 dnl CF_ANSI_CC_REQD version: 4 updated: 2008/03/23 14:48:54
 415 dnl ---------------
 416 dnl For programs that must use an ANSI compiler, obtain compiler options that
 417 dnl will make it recognize prototypes.  We'll do preprocessor checks in other
 418 dnl macros, since tools such as unproto can fake prototypes, but only part of
 419 dnl the preprocessor.
 420 AC_DEFUN([CF_ANSI_CC_REQD],
 421 [AC_REQUIRE([CF_ANSI_CC_CHECK])
 422 if test "$cf_cv_ansi_cc" = "no"; then
 423         AC_MSG_ERROR(
 424 [Your compiler does not appear to recognize prototypes.
 425 You have the following choices:
 426         a. adjust your compiler options
 427         b. get an up-to-date compiler
 428         c. use a wrapper such as unproto])
 429 fi
 430 ])dnl
 431 dnl ---------------------------------------------------------------------------
 432 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 433 dnl --------------
 434 dnl Allow user to disable a normally-on option.
 435 AC_DEFUN([CF_ARG_DISABLE],
 436 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 437 dnl ---------------------------------------------------------------------------
 438 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 439 dnl -------------
 440 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 441 dnl values.
 442 dnl
 443 dnl Parameters:
 444 dnl $1 = option name
 445 dnl $2 = help-string
 446 dnl $3 = action to perform if option is not default
 447 dnl $4 = action if perform if option is default
 448 dnl $5 = default option value (either 'yes' or 'no')
 449 AC_DEFUN([CF_ARG_OPTION],
 450 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 451   if test "$enableval" != "$5" ; then
 452 ifelse([$3],,[    :]dnl
 453 ,[    $3]) ifelse([$4],,,[
 454   else
 455     $4])
 456   fi],[enableval=$5 ifelse([$4],,,[
 457   $4
 458 ])dnl
 459   ])])dnl
 460 dnl ---------------------------------------------------------------------------
 461 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 462 dnl -----------
 463 dnl Check for suitable "ar" (archiver) options for updating an archive.
 464 AC_DEFUN([CF_AR_FLAGS],[
 465 AC_REQUIRE([CF_PROG_AR])
 466
 467 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 468         cf_cv_ar_flags=unknown
 469         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 470         do
 471
 472                 # check if $ARFLAGS already contains this choice
 473                 if test "x$ARFLAGS" != "x" ; then
 474                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 475                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 476                                 cf_cv_ar_flags=
 477                                 break
 478                         fi
 479                 fi
 480
 481                 rm -f conftest.$ac_cv_objext
 482                 rm -f conftest.a
 483
 484                 cat >conftest.$ac_ext <<EOF
 485 #line __oline__ "configure"
 486 int     testdata[[3]] = { 123, 456, 789 };
 487 EOF
 488                 if AC_TRY_EVAL(ac_compile) ; then
 489                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 490                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 491                         if test -f conftest.a ; then
 492                                 cf_cv_ar_flags=$cf_ar_flags
 493                                 break
 494                         fi
 495                 else
 496                         CF_VERBOSE(cannot compile test-program)
 497                         break
 498                 fi
 499         done
 500         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 501 ])
 502
 503 if test -n "$ARFLAGS" ; then
 504         if test -n "$cf_cv_ar_flags" ; then
 505                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 506         fi
 507 else
 508         ARFLAGS=$cf_cv_ar_flags
 509 fi
 510
 511 AC_SUBST(ARFLAGS)
 512 ])
 513 dnl ---------------------------------------------------------------------------
 514 dnl CF_AWK_BIG_PRINTF version: 4 updated: 2011/10/30 17:09:50
 515 dnl -----------------
 516 dnl Check if awk can handle big strings using printf.  Some older versions of
 517 dnl awk choke on large strings passed via "%s".
 518 dnl
 519 dnl $1 = desired string size
 520 dnl $2 = variable to set with result
 521 AC_DEFUN([CF_AWK_BIG_PRINTF],
 522 [
 523         case x$AWK in #(vi
 524         x)
 525                 eval $2=no
 526                 ;;
 527         *) #(vi
 528                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 529                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 530                         eval $2=yes
 531                 else
 532                         eval $2=no
 533                 fi
 534                 ;;
 535         esac
 536 ])dnl
 537 dnl ---------------------------------------------------------------------------
 538 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 539 dnl ------------
 540 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 541 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 542 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 543 dnl
 544 dnl Treat the configuration-variable specially here, since we're directly
 545 dnl substituting its value (i.e., 1/0).
 546 dnl
 547 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 548 AC_DEFUN([CF_BOOL_DECL],
 549 [
 550 AC_MSG_CHECKING(if we should include stdbool.h)
 551
 552 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 553         AC_TRY_COMPILE([],[bool foo = false],
 554                 [cf_cv_header_stdbool_h=0],
 555                 [AC_TRY_COMPILE([
 556 #ifndef __BEOS__
 557 #include <stdbool.h>
 558 #endif
 559 ],[bool foo = false],
 560                         [cf_cv_header_stdbool_h=1],
 561                         [cf_cv_header_stdbool_h=0])])])
 562
 563 if test "$cf_cv_header_stdbool_h" = 1
 564 then    AC_MSG_RESULT(yes)
 565 else    AC_MSG_RESULT(no)
 566 fi
 567
 568 AC_MSG_CHECKING([for builtin bool type])
 569
 570 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 571         AC_TRY_COMPILE([
 572 #include <stdio.h>
 573 #include <sys/types.h>
 574 ],[bool x = false],
 575                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 576                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 577         ])
 578
 579 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 580 then    AC_MSG_RESULT(yes)
 581 else    AC_MSG_RESULT(no)
 582 fi
 583 ])dnl
 584 dnl ---------------------------------------------------------------------------
 585 dnl CF_BOOL_SIZE version: 12 updated: 2006/12/16 12:33:30
 586 dnl ------------
 587 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 588 dnl Don't bother looking for bool.h, since it's been deprecated.
 589 dnl
 590 dnl If the current compiler is C rather than C++, we get the bool definition
 591 dnl from <stdbool.h>.
 592 AC_DEFUN([CF_BOOL_SIZE],
 593 [
 594 AC_MSG_CHECKING([for size of bool])
 595 AC_CACHE_VAL(cf_cv_type_of_bool,[
 596         rm -f cf_test.out
 597         AC_TRY_RUN([
 598 #include <stdlib.h>
 599 #include <stdio.h>
 600
 601 #if defined(__cplusplus)
 602
 603 #ifdef HAVE_GXX_BUILTIN_H
 604 #include <g++/builtin.h>
 605 #elif HAVE_GPP_BUILTIN_H
 606 #include <gpp/builtin.h>
 607 #elif HAVE_BUILTIN_H
 608 #include <builtin.h>
 609 #endif
 610
 611 #else
 612
 613 #if $cf_cv_header_stdbool_h
 614 #include <stdbool.h>
 615 #endif
 616
 617 #endif
 618
 619 main()
 620 {
 621         FILE *fp = fopen("cf_test.out", "w");
 622         if (fp != 0) {
 623                 bool x = true;
 624                 if ((bool)(-x) >= 0)
 625                         fputs("unsigned ", fp);
 626                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 627                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 628                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 629                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 630                 fclose(fp);
 631         }
 632         ${cf_cv_main_return:-return}(0);
 633 }
 634                 ],
 635                 [cf_cv_type_of_bool=`cat cf_test.out`
 636                  if test -z "$cf_cv_type_of_bool"; then
 637                    cf_cv_type_of_bool=unknown
 638                  fi],
 639                 [cf_cv_type_of_bool=unknown],
 640                 [cf_cv_type_of_bool=unknown])
 641         ])
 642         rm -f cf_test.out
 643 AC_MSG_RESULT($cf_cv_type_of_bool)
 644 if test "$cf_cv_type_of_bool" = unknown ; then
 645         case .$NCURSES_BOOL in #(vi
 646         .auto|.) NCURSES_BOOL=unsigned;;
 647         esac
 648         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 649         cf_cv_type_of_bool=$NCURSES_BOOL
 650 fi
 651 ])dnl
 652 dnl ---------------------------------------------------------------------------
 653 dnl CF_BUILD_CC version: 6 updated: 2006/10/14 15:23:15
 654 dnl -----------
 655 dnl If we're cross-compiling, allow the user to override the tools and their
 656 dnl options.  The configure script is oriented toward identifying the host
 657 dnl compiler, etc., but we need a build compiler to generate parts of the
 658 dnl source.
 659 dnl
 660 dnl $1 = default for $CPPFLAGS
 661 dnl $2 = default for $LIBS
 662 AC_DEFUN([CF_BUILD_CC],[
 663 AC_REQUIRE([CF_PROG_EXT])
 664 if test "$cross_compiling" = yes ; then
 665
 666         # defaults that we might want to override
 667         : ${BUILD_CFLAGS:=''}
 668         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 669         : ${BUILD_LDFLAGS:=''}
 670         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 671         : ${BUILD_EXEEXT:='$x'}
 672         : ${BUILD_OBJEXT:='o'}
 673
 674         AC_ARG_WITH(build-cc,
 675                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 676                 [BUILD_CC="$withval"],
 677                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 678         AC_MSG_CHECKING(for native build C compiler)
 679         AC_MSG_RESULT($BUILD_CC)
 680
 681         AC_MSG_CHECKING(for native build C preprocessor)
 682         AC_ARG_WITH(build-cpp,
 683                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 684                 [BUILD_CPP="$withval"],
 685                 [BUILD_CPP='${BUILD_CC} -E'])
 686         AC_MSG_RESULT($BUILD_CPP)
 687
 688         AC_MSG_CHECKING(for native build C flags)
 689         AC_ARG_WITH(build-cflags,
 690                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 691                 [BUILD_CFLAGS="$withval"])
 692         AC_MSG_RESULT($BUILD_CFLAGS)
 693
 694         AC_MSG_CHECKING(for native build C preprocessor-flags)
 695         AC_ARG_WITH(build-cppflags,
 696                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 697                 [BUILD_CPPFLAGS="$withval"])
 698         AC_MSG_RESULT($BUILD_CPPFLAGS)
 699
 700         AC_MSG_CHECKING(for native build linker-flags)
 701         AC_ARG_WITH(build-ldflags,
 702                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 703                 [BUILD_LDFLAGS="$withval"])
 704         AC_MSG_RESULT($BUILD_LDFLAGS)
 705
 706         AC_MSG_CHECKING(for native build linker-libraries)
 707         AC_ARG_WITH(build-libs,
 708                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 709                 [BUILD_LIBS="$withval"])
 710         AC_MSG_RESULT($BUILD_LIBS)
 711
 712         # this assumes we're on Unix.
 713         BUILD_EXEEXT=
 714         BUILD_OBJEXT=o
 715
 716         : ${BUILD_CC:='${CC}'}
 717
 718         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 719                 AC_MSG_ERROR([Cross-build requires two compilers.
 720 Use --with-build-cc to specify the native compiler.])
 721         fi
 722
 723 else
 724         : ${BUILD_CC:='${CC}'}
 725         : ${BUILD_CPP:='${CPP}'}
 726         : ${BUILD_CFLAGS:='${CFLAGS}'}
 727         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 728         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 729         : ${BUILD_LIBS:='${LIBS}'}
 730         : ${BUILD_EXEEXT:='$x'}
 731         : ${BUILD_OBJEXT:='o'}
 732 fi
 733
 734 AC_SUBST(BUILD_CC)
 735 AC_SUBST(BUILD_CPP)
 736 AC_SUBST(BUILD_CFLAGS)
 737 AC_SUBST(BUILD_CPPFLAGS)
 738 AC_SUBST(BUILD_LDFLAGS)
 739 AC_SUBST(BUILD_LIBS)
 740 AC_SUBST(BUILD_EXEEXT)
 741 AC_SUBST(BUILD_OBJEXT)
 742 ])dnl
 743 dnl ---------------------------------------------------------------------------
 744 dnl CF_CFG_DEFAULTS version: 8 updated: 2011/06/04 20:09:13
 745 dnl ---------------
 746 dnl Determine the default configuration into which we'll install ncurses.  This
 747 dnl can be overridden by the user's command-line options.  There's two items to
 748 dnl look for:
 749 dnl     1. the prefix (e.g., /usr)
 750 dnl     2. the header files (e.g., /usr/include/ncurses)
 751 dnl We'll look for a previous installation of ncurses and use the same defaults.
 752 dnl
 753 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 754 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 755 dnl programs from a vendor's.
 756 AC_DEFUN([CF_CFG_DEFAULTS],
 757 [
 758 AC_MSG_CHECKING(for prefix)
 759 if test "x$prefix" = "xNONE" ; then
 760         case "$cf_cv_system_name" in
 761                 # non-vendor systems don't have a conflict
 762         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|k*bsd*-gnu)
 763                 prefix=/usr
 764                 ;;
 765         *)      prefix=$ac_default_prefix
 766                 ;;
 767         esac
 768 fi
 769 AC_MSG_RESULT($prefix)
 770
 771 if test "x$prefix" = "xNONE" ; then
 772 AC_MSG_CHECKING(for default include-directory)
 773 test -n "$verbose" && echo 1>&AC_FD_MSG
 774 for cf_symbol in \
 775         $includedir \
 776         $includedir/ncurses \
 777         $prefix/include \
 778         $prefix/include/ncurses \
 779         /usr/local/include \
 780         /usr/local/include/ncurses \
 781         /usr/include \
 782         /usr/include/ncurses
 783 do
 784         cf_dir=`eval echo $cf_symbol`
 785         if test -f $cf_dir/curses.h ; then
 786         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 787                 includedir="$cf_symbol"
 788                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 789                 break
 790         fi
 791         fi
 792         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 793 done
 794 AC_MSG_RESULT($includedir)
 795 fi
 796 ])dnl
 797 dnl ---------------------------------------------------------------------------
 798 dnl CF_CGETENT version: 4 updated: 2011/08/07 14:54:41
 799 dnl ----------
 800 dnl Check if the terminal-capability database functions are available.  If not,
 801 dnl ncurses has a much-reduced version.
 802 AC_DEFUN([CF_CGETENT],[
 803 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 804 AC_TRY_LINK([
 805 #include <stdlib.h>],[
 806         char temp[128];
 807         char *buf = temp;
 808         char *db_array = temp;
 809         cgetent(&buf, &db_array, "vt100");
 810         cgetcap(buf, "tc", '=');
 811         cgetmatch(buf, "tc");
 812         ],
 813         [cf_cv_cgetent=yes],
 814         [cf_cv_cgetent=no])
 815 ])
 816
 817 if test "$cf_cv_cgetent" = yes
 818 then
 819         AC_DEFINE(HAVE_BSD_CGETENT)
 820 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 821 AC_TRY_LINK([
 822 #include <stdlib.h>],[
 823         char temp[128];
 824         char *buf = temp;
 825 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 826         const char *db_array = temp;
 827         cgetent(&buf, &db_array, "vt100");
 828 #endif
 829         cgetcap(buf, "tc", '=');
 830         cgetmatch(buf, "tc");
 831         ],
 832         [cf_cv_cgetent_const=yes],
 833         [cf_cv_cgetent_const=no])
 834 ])
 835         if test "$cf_cv_cgetent_const" = yes
 836         then
 837                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const)
 838         fi
 839 fi
 840 ])dnl
 841 dnl ---------------------------------------------------------------------------
 842 dnl CF_CHECK_CACHE version: 11 updated: 2008/03/23 14:45:59
 843 dnl --------------
 844 dnl Check if we're accidentally using a cache from a different machine.
 845 dnl Derive the system name, as a check for reusing the autoconf cache.
 846 dnl
 847 dnl If we've packaged config.guess and config.sub, run that (since it does a
 848 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 849 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 850 dnl which is useful in cross-compiles.
 851 dnl
 852 dnl Note: we would use $ac_config_sub, but that is one of the places where
 853 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 854 AC_DEFUN([CF_CHECK_CACHE],
 855 [
 856 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 857         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 858         system_name="$host_os"
 859 else
 860         system_name="`(uname -s -r) 2>/dev/null`"
 861         if test -z "$system_name" ; then
 862                 system_name="`(hostname) 2>/dev/null`"
 863         fi
 864 fi
 865 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name")
 866 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 867
 868 test -z "$system_name" && system_name="$cf_cv_system_name"
 869 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 870
 871 if test ".$system_name" != ".$cf_cv_system_name" ; then
 872         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 873         AC_MSG_ERROR("Please remove config.cache and try again.")
 874 fi
 875 ])dnl
 876 dnl ---------------------------------------------------------------------------
 877 dnl CF_CHECK_ERRNO version: 11 updated: 2010/05/26 05:38:42
 878 dnl --------------
 879 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 880 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 881 dnl ourselves.
 882 dnl
 883 dnl $1 = the name to check
 884 dnl $2 = the assumed type
 885 AC_DEFUN([CF_CHECK_ERRNO],
 886 [
 887 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 888     AC_TRY_COMPILE([
 889 #ifdef HAVE_STDLIB_H
 890 #include <stdlib.h>
 891 #endif
 892 #include <stdio.h>
 893 #include <sys/types.h>
 894 #include <errno.h> ],
 895     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 896     [cf_cv_dcl_$1=yes],
 897     [cf_cv_dcl_$1=no])
 898 ])
 899
 900 if test "$cf_cv_dcl_$1" = no ; then
 901     CF_UPPER(cf_result,decl_$1)
 902     AC_DEFINE_UNQUOTED($cf_result)
 903 fi
 904
 905 # It's possible (for near-UNIX clones) that the data doesn't exist
 906 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 907 ])dnl
 908 dnl ---------------------------------------------------------------------------
 909 dnl CF_CHECK_EXTERN_DATA version: 3 updated: 2001/12/30 18:03:23
 910 dnl --------------------
 911 dnl Check for existence of external data in the current set of libraries.  If
 912 dnl we can modify it, it's real enough.
 913 dnl $1 = the name to check
 914 dnl $2 = its type
 915 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 916 [
 917 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 918     AC_TRY_LINK([
 919 #undef $1
 920 extern $2 $1;
 921 ],
 922     [$1 = 2],
 923     [cf_cv_have_$1=yes],
 924     [cf_cv_have_$1=no])
 925 ])
 926
 927 if test "$cf_cv_have_$1" = yes ; then
 928     CF_UPPER(cf_result,have_$1)
 929     AC_DEFINE_UNQUOTED($cf_result)
 930 fi
 931
 932 ])dnl
 933 dnl ---------------------------------------------------------------------------
 934 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 935 dnl -------------------
 936 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 937 dnl is not "weak" - warn about this because it can create problems linking
 938 dnl applications with ncurses.
 939 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 940 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 941
 942 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 943 cf_cv_check_gpm_wgetch=unknown
 944 if test "$cross_compiling" != yes ; then
 945
 946 cat >conftest.$ac_ext <<CF_EOF
 947 #include <gpm.h>
 948 int main()
 949 {
 950         Gpm_Wgetch();
 951         ${cf_cv_main_return:-return}(0);
 952 }
 953 CF_EOF
 954
 955         cf_save_LIBS="$LIBS"
 956         # This only works if we can look at the symbol table.  If a shared
 957         # library is stripped for install, we cannot use that.  So we're forced
 958         # to rely on the static library, noting that some packagers may not
 959         # include it.
 960         LIBS="-static -lgpm -dynamic $LIBS"
 961         if AC_TRY_EVAL(ac_compile) ; then
 962                 if AC_TRY_EVAL(ac_link) ; then
 963                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 964                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 965                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 966                 fi
 967         fi
 968         rm -rf conftest*
 969         LIBS="$cf_save_LIBS"
 970 fi
 971 ])
 972
 973 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 974         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 975 fi
 976 ])])dnl
 977 dnl ---------------------------------------------------------------------------
 978 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
 979 dnl ----------------
 980 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
 981 AC_DEFUN([CF_CHECK_WCHAR_H],[
 982 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
 983 AC_TRY_COMPILE(
 984 [
 985 #include <stdlib.h>
 986 #include <wchar.h>
 987 ],[
 988         wint_t foo = 0;
 989         int bar = iswpunct(foo)],
 990         [cf_cv_wchar_h_okay=yes],
 991         [cf_cv_wchar_h_okay=no])])
 992
 993 if test $cf_cv_wchar_h_okay = no
 994 then
 995         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 996 fi
 997 ])dnl
 998 dnl ---------------------------------------------------------------------------
 999 dnl CF_CLANG_COMPILER version: 1 updated: 2012/06/16 14:55:39
1000 dnl -----------------
1001 dnl Check if the given compiler is really clang.  clang's C driver defines
1002 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1003 dnl not ignore some gcc options.
1004 dnl
1005 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1006 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1007 dnl the wrappers for gcc and g++ warnings.
1008 dnl
1009 dnl $1 = GCC (default) or GXX
1010 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1011 dnl $3 = CFLAGS (default) or CXXFLAGS
1012 AC_DEFUN([CF_CLANG_COMPILER],[
1013 ifelse([$2],,CLANG_COMPILER,[$2])=no
1014
1015 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1016         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1017         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1018         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
1019         AC_TRY_COMPILE([],[
1020 #ifdef __clang__
1021 #else
1022 make an error
1023 #endif
1024 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1025 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1026 ],[])
1027         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1028         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1029 fi
1030 ])
1031 dnl ---------------------------------------------------------------------------
1032 dnl CF_CPP_PARAM_INIT version: 5 updated: 2011/12/03 16:54:03
1033 dnl -----------------
1034 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1035 dnl is a late feature for the standard and is not in some recent compilers
1036 dnl (1999/9/11).
1037 AC_DEFUN([CF_CPP_PARAM_INIT],
1038 [
1039 if test -n "$CXX"; then
1040 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1041         AC_LANG_SAVE
1042         AC_LANG_CPLUSPLUS
1043         AC_TRY_RUN([
1044 class TEST {
1045 private:
1046         int value;
1047 public:
1048         TEST(int x = 1);
1049         ~TEST();
1050 };
1051
1052 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1053 {
1054         value = x;
1055 }
1056 int main() { }
1057 ],
1058         [cf_cv_cpp_param_init=yes],
1059         [cf_cv_cpp_param_init=no],
1060         [cf_cv_cpp_param_init=unknown])
1061         AC_LANG_RESTORE
1062 ])
1063 fi
1064 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT)
1065 ])dnl
1066 dnl ---------------------------------------------------------------------------
1067 dnl CF_CPP_STATIC_CAST version: 1 updated: 2005/07/23 16:52:43
1068 dnl ------------------
1069 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1070 dnl not be supported in g++ before 3.0
1071 AC_DEFUN([CF_CPP_STATIC_CAST],
1072 [
1073 if test -n "$CXX"; then
1074
1075 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1076         AC_LANG_SAVE
1077         AC_LANG_CPLUSPLUS
1078
1079         AC_TRY_COMPILE([
1080 class NCursesPanel
1081 {
1082 public:
1083   NCursesPanel(int nlines,
1084                int ncols,
1085                int begin_y = 0,
1086                int begin_x = 0)
1087   {
1088   }
1089
1090   ~NCursesPanel();
1091 };
1092
1093 template<class T> class NCursesUserPanel : public NCursesPanel
1094 {
1095 public:
1096   NCursesUserPanel (int nlines,
1097                     int ncols,
1098                     int begin_y = 0,
1099                     int begin_x = 0,
1100                     const T* p_UserData = static_cast<T*>(0))
1101     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1102   {
1103   };
1104   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1105   {
1106   };
1107
1108   virtual ~NCursesUserPanel() {};
1109 };
1110 ],[
1111         const char* p_UserData = static_cast<char*>(0)],
1112         [cf_cv_cpp_static_cast=yes],
1113         [cf_cv_cpp_static_cast=no])
1114
1115         AC_LANG_RESTORE
1116 ])
1117
1118 fi
1119
1120 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST)
1121 ])dnl
1122 dnl ---------------------------------------------------------------------------
1123 dnl CF_CXX_AR_FLAGS version: 1 updated: 2011/10/29 08:35:34
1124 dnl ---------------
1125 dnl Setup special archiver flags for given compilers.
1126 AC_DEFUN([CF_CXX_AR_FLAGS],[
1127         CXX_AR='$(AR)'
1128         CXX_ARFLAGS='$(ARFLAGS)'
1129         case $cf_cv_system_name in #(vi
1130         irix*) #(vi
1131             if test "$GXX" != yes ; then
1132                 CXX_AR='$(CXX)'
1133                 CXX_ARFLAGS='-ar -o'
1134             fi
1135             ;;
1136         sco3.2v5*) #(vi
1137             CXXLDFLAGS="-u main"
1138             ;;
1139         solaris2*)
1140             if test "$GXX" != yes ; then
1141                 CXX_AR='$(CXX)'
1142                 CXX_ARFLAGS='-xar -o'
1143             fi
1144             ;;
1145         esac
1146         AC_SUBST(CXXLDFLAGS)
1147         AC_SUBST(CXX_AR)
1148         AC_SUBST(CXX_ARFLAGS)
1149 ])dnl
1150 dnl ---------------------------------------------------------------------------
1151 dnl CF_CXX_IOSTREAM_NAMESPACE version: 1 updated: 2011/10/29 08:35:34
1152 dnl -------------------------
1153 dnl For c++, check if iostream uses "std::" namespace.
1154 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1155 AC_CHECK_HEADERS(iostream)
1156 if test x"$ac_cv_header_iostream" = xyes ; then
1157         AC_MSG_CHECKING(if iostream uses std-namespace)
1158         AC_TRY_COMPILE([
1159 #include <iostream>
1160 using std::endl;
1161 using std::cerr;],[
1162 cerr << "testing" << endl;
1163 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1164         AC_MSG_RESULT($cf_iostream_namespace)
1165         if test "$cf_iostream_namespace" = yes ; then
1166                 AC_DEFINE(IOSTREAM_NAMESPACE)
1167         fi
1168 fi
1169 ])dnl
1170 dnl ---------------------------------------------------------------------------
1171 dnl CF_C_INLINE version: 4 updated: 2012/06/16 14:55:39
1172 dnl -----------
1173 dnl Check if the C compiler supports "inline".
1174 dnl $1 is the name of a shell variable to set if inline is supported
1175 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1176 AC_DEFUN([CF_C_INLINE],[
1177 AC_C_INLINE
1178 $1=
1179 if test "$ac_cv_c_inline" != no ; then
1180   $1=inline
1181   if test "$INTEL_COMPILER" = yes
1182   then
1183     :
1184   elif test "$CLANG_COMPILER" = yes
1185   then
1186     :
1187   elif test "$GCC" = yes
1188   then
1189     AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1190       cf_save_CFLAGS=$CFLAGS
1191       CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1192       AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1193       [${cf_cv_main_return:-return} foo()],
1194       [cf_cv_gcc_inline=yes],
1195       [cf_cv_gcc_inline=no])
1196       CFLAGS=$cf_save_CFLAGS
1197     ])
1198     if test "$cf_cv_gcc_inline" = yes ; then
1199         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1200     fi
1201   fi
1202 fi
1203 AC_SUBST($1)
1204 ])dnl
1205 dnl ---------------------------------------------------------------------------
1206 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1207 dnl ----------
1208 dnl "dirname" is not portable, so we fake it with a shell script.
1209 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1210 dnl ---------------------------------------------------------------------------
1211 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1212 dnl ---------------
1213 AC_DEFUN([CF_DIRS_TO_MAKE],
1214 [
1215 DIRS_TO_MAKE="lib"
1216 for cf_item in $cf_list_models
1217 do
1218         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1219         for cf_item2 in $DIRS_TO_MAKE
1220         do
1221                 test $cf_item2 = $cf_subdir && break
1222         done
1223         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1224 done
1225 for cf_dir in $DIRS_TO_MAKE
1226 do
1227         test ! -d $cf_dir && mkdir $cf_dir
1228 done
1229 AC_SUBST(DIRS_TO_MAKE)
1230 ])dnl
1231 dnl ---------------------------------------------------------------------------
1232 dnl CF_DISABLE_ECHO version: 11 updated: 2009/12/13 13:16:57
1233 dnl ---------------
1234 dnl You can always use "make -n" to see the actual options, but it's hard to
1235 dnl pick out/analyze warning messages when the compile-line is long.
1236 dnl
1237 dnl Sets:
1238 dnl     ECHO_LT - symbol to control if libtool is verbose
1239 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1240 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1241 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1242 dnl     ECHO_CC - symbol to put before any "cc" line
1243 dnl
1244 AC_DEFUN([CF_DISABLE_ECHO],[
1245 AC_MSG_CHECKING(if you want to see long compiling messages)
1246 CF_ARG_DISABLE(echo,
1247         [  --disable-echo          display "compiling" commands],
1248         [
1249     ECHO_LT='--silent'
1250     ECHO_LD='@echo linking [$]@;'
1251     RULE_CC='@echo compiling [$]<'
1252     SHOW_CC='@echo compiling [$]@'
1253     ECHO_CC='@'
1254 ],[
1255     ECHO_LT=''
1256     ECHO_LD=''
1257     RULE_CC=''
1258     SHOW_CC=''
1259     ECHO_CC=''
1260 ])
1261 AC_MSG_RESULT($enableval)
1262 AC_SUBST(ECHO_LT)
1263 AC_SUBST(ECHO_LD)
1264 AC_SUBST(RULE_CC)
1265 AC_SUBST(SHOW_CC)
1266 AC_SUBST(ECHO_CC)
1267 ])dnl
1268 dnl ---------------------------------------------------------------------------
1269 dnl CF_DISABLE_LEAKS version: 6 updated: 2010/07/23 04:14:32
1270 dnl ----------------
1271 dnl Combine no-leak checks with the libraries or tools that are used for the
1272 dnl checks.
1273 AC_DEFUN([CF_DISABLE_LEAKS],[
1274
1275 AC_REQUIRE([CF_WITH_DMALLOC])
1276 AC_REQUIRE([CF_WITH_DBMALLOC])
1277 AC_REQUIRE([CF_WITH_VALGRIND])
1278
1279 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1280 AC_ARG_ENABLE(leaks,
1281         [  --disable-leaks         test: free permanent memory, analyze leaks],
1282         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1283         : ${with_no_leaks:=no})
1284 AC_MSG_RESULT($with_no_leaks)
1285
1286 if test "$with_no_leaks" = yes ; then
1287         AC_DEFINE(NO_LEAKS)
1288         AC_DEFINE(YY_NO_LEAKS)
1289 fi
1290 ])dnl
1291 dnl ---------------------------------------------------------------------------
1292 dnl CF_DISABLE_LIBTOOL_VERSION version: 1 updated: 2010/05/15 15:45:59
1293 dnl --------------------------
1294 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1295 dnl the older "-version-info" feature.  The newer feature allows us to use
1296 dnl version numbering on shared libraries which make them compatible with
1297 dnl various systems.
1298 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1299 [
1300 AC_MSG_CHECKING(if libtool -version-number should be used)
1301 CF_ARG_DISABLE(libtool-version,
1302         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1303         [cf_libtool_version=no],
1304         [cf_libtool_version=yes])
1305 AC_MSG_RESULT($cf_libtool_version)
1306
1307 if test "$cf_libtool_version" = yes ; then
1308         LIBTOOL_VERSION="-version-number"
1309 else
1310         LIBTOOL_VERSION="-version-info"
1311 fi
1312
1313 AC_SUBST(LIBTOOL_VERSION)
1314 ])dnl
1315 dnl ---------------------------------------------------------------------------
1316 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1317 dnl ---------------------
1318 dnl The rpath-hack makes it simpler to build programs, particularly with the
1319 dnl *BSD ports which may have essential libraries in unusual places.  But it
1320 dnl can interfere with building an executable for the base system.  Use this
1321 dnl option in that case.
1322 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1323 [
1324 AC_MSG_CHECKING(if rpath-hack should be disabled)
1325 CF_ARG_DISABLE(rpath-hack,
1326         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1327         [cf_disable_rpath_hack=yes],
1328         [cf_disable_rpath_hack=no])
1329 AC_MSG_RESULT($cf_disable_rpath_hack)
1330 if test "$cf_disable_rpath_hack" = no ; then
1331         CF_RPATH_HACK
1332 fi
1333 ])
1334 dnl ---------------------------------------------------------------------------
1335 dnl CF_ENABLE_PC_FILES version: 9 updated: 2012/08/04 13:59:54
1336 dnl ------------------
1337 dnl This is the "--enable-pc-files" option, which is available if there is a
1338 dnl pkg-config configuration on the local machine.
1339 AC_DEFUN([CF_ENABLE_PC_FILES],[
1340 AC_REQUIRE([CF_PKG_CONFIG])
1341 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1342
1343 if test "$PKG_CONFIG" != none ; then
1344         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1345         AC_ARG_ENABLE(pc-files,
1346                 [  --enable-pc-files       generate and install .pc files for pkg-config],
1347                 [enable_pc_files=$enableval],
1348                 [enable_pc_files=no])
1349         AC_MSG_RESULT($enable_pc_files)
1350         if test "$enable_pc_files" != no
1351         then
1352                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1353         fi
1354 else
1355         enable_pc_files=no
1356 fi
1357 ])dnl
1358 dnl ---------------------------------------------------------------------------
1359 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1360 dnl ---------------
1361 dnl Check if the rpath option should be used, setting cache variable
1362 dnl cf_cv_enable_rpath if so.
1363 AC_DEFUN([CF_ENABLE_RPATH],
1364 [
1365 AC_MSG_CHECKING(if rpath option should be used)
1366 AC_ARG_ENABLE(rpath,
1367 [  --enable-rpath          use rpath option when generating shared libraries],
1368 [cf_cv_enable_rpath=$enableval],
1369 [cf_cv_enable_rpath=no])
1370 AC_MSG_RESULT($cf_cv_enable_rpath)
1371 ])dnl
1372 dnl ---------------------------------------------------------------------------
1373 dnl CF_ENABLE_STRING_HACKS version: 1 updated: 2012/02/25 06:33:21
1374 dnl ----------------------
1375 dnl On a few platforms, the compiler and/or loader nags with untruthful
1376 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1377 dnl and implying that most uses of the recommended alternatives are correct.
1378 dnl
1379 dnl Factually speaking, no one has actually counted the number of uses of these
1380 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1381 dnl instances are meaningless compared to the hundreds of millions of lines of
1382 dnl existing C code.
1383 dnl
1384 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1385 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1386 dnl standard - but evolved through phases, and older implementations are likely
1387 dnl to yield surprising results, as documented in manpages on various systems.
1388 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1389 [
1390 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1391 AC_ARG_ENABLE(string-hacks,
1392         [  --enable-string-hacks  work around bogus compiler/loader warnings],
1393         [with_string_hacks=$enableval],
1394         [with_string_hacks=no])
1395 AC_MSG_RESULT($with_string_hacks)
1396
1397 if test "x$with_string_hacks" = "xyes"; then
1398         AC_DEFINE(USE_STRING_HACKS)
1399         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1400         AC_CHECK_FUNCS( strlcat strlcpy snprintf )
1401 fi
1402 ])dnl
1403 dnl ---------------------------------------------------------------------------
1404 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1405 dnl --------
1406 dnl Check if 'errno' is declared in <errno.h>
1407 AC_DEFUN([CF_ERRNO],
1408 [
1409 CF_CHECK_ERRNO(errno)
1410 ])dnl
1411 dnl ---------------------------------------------------------------------------
1412 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1413 dnl ---------------
1414 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1415 dnl math.h and builtin.h, only for ncurses
1416 AC_DEFUN([CF_ETIP_DEFINES],
1417 [
1418 AC_MSG_CHECKING(for special defines needed for etip.h)
1419 cf_save_CXXFLAGS="$CXXFLAGS"
1420 cf_result="none"
1421
1422 # etip.h includes ncurses.h which includes ncurses_dll.h
1423 # But ncurses_dll.h is generated - fix here.
1424 test -d include || mkdir include
1425 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1426
1427 for cf_math in "" MATH_H
1428 do
1429 for cf_excp in "" MATH_EXCEPTION
1430 do
1431         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1432         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1433         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1434 AC_TRY_COMPILE([
1435 #include <etip.h.in>
1436 ],[],[
1437         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1438         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1439         cf_result="$cf_math $cf_excp"
1440         break 2
1441 ],[])
1442 done
1443 done
1444 AC_MSG_RESULT($cf_result)
1445 CXXFLAGS="$cf_save_CXXFLAGS"
1446 ])
1447 dnl ---------------------------------------------------------------------------
1448 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1449 dnl ---------------
1450 dnl Find a library (specifically the linkage used in the code fragment),
1451 dnl searching for it if it is not already in the library path.
1452 dnl See also CF_ADD_SEARCHPATH.
1453 dnl
1454 dnl Parameters (4-on are optional):
1455 dnl     $1 = headers for library entrypoint
1456 dnl     $2 = code fragment for library entrypoint
1457 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1458 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1459 dnl     $5 = action to perform if not successful
1460 dnl     $6 = module name, if not the same as the library name
1461 dnl     $7 = extra libraries
1462 dnl
1463 dnl Sets these variables:
1464 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1465 dnl     $cf_cv_header_path_$3 - include-directory if needed
1466 dnl     $cf_cv_library_path_$3 - library-directory if needed
1467 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1468 AC_DEFUN([CF_FIND_LINKAGE],[
1469
1470 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1471 # will be set on completion of the AC_TRY_LINK below.
1472 cf_cv_header_path_$3=
1473 cf_cv_library_path_$3=
1474
1475 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1476
1477 cf_save_LIBS="$LIBS"
1478
1479 AC_TRY_LINK([$1],[$2],[
1480         cf_cv_find_linkage_$3=yes
1481         cf_cv_header_path_$3=/usr/include
1482         cf_cv_library_path_$3=/usr/lib
1483 ],[
1484
1485 LIBS="-l$3 $7 $cf_save_LIBS"
1486
1487 AC_TRY_LINK([$1],[$2],[
1488         cf_cv_find_linkage_$3=yes
1489         cf_cv_header_path_$3=/usr/include
1490         cf_cv_library_path_$3=/usr/lib
1491         cf_cv_library_file_$3="-l$3"
1492 ],[
1493         cf_cv_find_linkage_$3=no
1494         LIBS="$cf_save_LIBS"
1495
1496     CF_VERBOSE(find linkage for $3 library)
1497     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1498
1499     cf_save_CPPFLAGS="$CPPFLAGS"
1500     cf_test_CPPFLAGS="$CPPFLAGS"
1501
1502     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1503     for cf_cv_header_path_$3 in $cf_search
1504     do
1505       if test -d $cf_cv_header_path_$3 ; then
1506         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1507         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1508         AC_TRY_COMPILE([$1],[$2],[
1509             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1510             cf_cv_find_linkage_$3=maybe
1511             cf_test_CPPFLAGS="$CPPFLAGS"
1512             break],[
1513             CPPFLAGS="$cf_save_CPPFLAGS"
1514             ])
1515       fi
1516     done
1517
1518     if test "$cf_cv_find_linkage_$3" = maybe ; then
1519
1520       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1521
1522       cf_save_LIBS="$LIBS"
1523       cf_save_LDFLAGS="$LDFLAGS"
1524
1525       ifelse([$6],,,[
1526         CPPFLAGS="$cf_test_CPPFLAGS"
1527         LIBS="-l$3 $7 $cf_save_LIBS"
1528         AC_TRY_LINK([$1],[$2],[
1529             CF_VERBOSE(... found $3 library in system)
1530             cf_cv_find_linkage_$3=yes])
1531             CPPFLAGS="$cf_save_CPPFLAGS"
1532             LIBS="$cf_save_LIBS"
1533             ])
1534
1535       if test "$cf_cv_find_linkage_$3" != yes ; then
1536         CF_LIBRARY_PATH(cf_search,$3)
1537         for cf_cv_library_path_$3 in $cf_search
1538         do
1539           if test -d $cf_cv_library_path_$3 ; then
1540             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1541             CPPFLAGS="$cf_test_CPPFLAGS"
1542             LIBS="-l$3 $7 $cf_save_LIBS"
1543             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1544             AC_TRY_LINK([$1],[$2],[
1545                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1546                 cf_cv_find_linkage_$3=yes
1547                 cf_cv_library_file_$3="-l$3"
1548                 break],[
1549                 CPPFLAGS="$cf_save_CPPFLAGS"
1550                 LIBS="$cf_save_LIBS"
1551                 LDFLAGS="$cf_save_LDFLAGS"
1552                 ])
1553           fi
1554         done
1555         CPPFLAGS="$cf_save_CPPFLAGS"
1556         LDFLAGS="$cf_save_LDFLAGS"
1557       fi
1558
1559     else
1560       cf_cv_find_linkage_$3=no
1561     fi
1562     ],$7)
1563 ])
1564
1565 LIBS="$cf_save_LIBS"
1566
1567 if test "$cf_cv_find_linkage_$3" = yes ; then
1568 ifelse([$4],,[
1569         CF_ADD_INCDIR($cf_cv_header_path_$3)
1570         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1571         CF_ADD_LIB($3)
1572 ],[$4])
1573 else
1574 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1575 fi
1576 ])dnl
1577 dnl ---------------------------------------------------------------------------
1578 dnl CF_FIXUP_ADAFLAGS version: 1 updated: 2012/03/31 18:48:10
1579 dnl -----------------
1580 dnl make ADAFLAGS consistent with CFLAGS
1581 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1582         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1583         case "$CFLAGS" in
1584         *-g*)
1585                 CF_ADD_ADAFLAGS(-g)
1586                 ;;
1587         esac
1588         case "$CFLAGS" in
1589         *-O*)
1590                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1591                 CF_ADD_ADAFLAGS($cf_O_flag)
1592                 ;;
1593         esac
1594         AC_MSG_RESULT($ADAFLAGS)
1595 ])dnl
1596 dnl ---------------------------------------------------------------------------
1597 dnl CF_FUNC_DLSYM version: 2 updated: 2010/05/29 16:31:02
1598 dnl -------------
1599 dnl Test for dlsym() and related functions, as well as libdl.
1600 dnl
1601 dnl Sets
1602 dnl     $cf_have_dlsym
1603 dnl     $cf_have_libdl
1604 AC_DEFUN([CF_FUNC_DLSYM],[
1605 cf_have_dlsym=no
1606 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1607
1608 cf_have_libdl=no
1609 AC_CHECK_LIB(dl,dlsym,[
1610         cf_have_dlsym=yes
1611         cf_have_libdl=yes])])
1612
1613 if test "$cf_have_dlsym" = yes ; then
1614         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1615
1616         AC_MSG_CHECKING(whether able to link to dl*() functions)
1617         AC_TRY_LINK([#include <dlfcn.h>],[
1618                 void *obj;
1619                 if ((obj = dlopen("filename", 0)) != 0) {
1620                         if (dlsym(obj, "symbolname") == 0) {
1621                         dlclose(obj);
1622                         }
1623                 }],[
1624                 AC_DEFINE(HAVE_LIBDL)],[
1625                 AC_MSG_ERROR(Cannot link test program for libdl)])
1626         AC_MSG_RESULT(ok)
1627 else
1628         AC_MSG_ERROR(Cannot find dlsym function)
1629 fi
1630 ])
1631 dnl ---------------------------------------------------------------------------
1632 dnl CF_FUNC_MEMMOVE version: 7 updated: 2006/12/16 12:33:30
1633 dnl ---------------
1634 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1635 dnl is found, add our own version of memmove to the list of objects.
1636 AC_DEFUN([CF_FUNC_MEMMOVE],
1637 [
1638 AC_CHECK_FUNC(memmove,,[
1639 AC_CHECK_FUNC(bcopy,[
1640         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1641                 AC_TRY_RUN([
1642 int main() {
1643         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1644         char temp[40];
1645         bcopy(data, temp, sizeof(data));
1646         bcopy(temp+10, temp, 15);
1647         bcopy(temp+5, temp+15, 10);
1648         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1649 }
1650                 ],
1651                 [cf_cv_good_bcopy=yes],
1652                 [cf_cv_good_bcopy=no],
1653                 [cf_cv_good_bcopy=unknown])
1654                 ])
1655         ],[cf_cv_good_bcopy=no])
1656         if test "$cf_cv_good_bcopy" = yes ; then
1657                 AC_DEFINE(USE_OK_BCOPY)
1658         else
1659                 AC_DEFINE(USE_MY_MEMMOVE)
1660         fi
1661 ])])dnl
1662 dnl ---------------------------------------------------------------------------
1663 dnl CF_FUNC_NANOSLEEP version: 3 updated: 2006/12/16 12:33:30
1664 dnl -----------------
1665 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1666 dnl AIX 4.x, provide a non-working version.
1667 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1668 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1669 AC_TRY_RUN([
1670 #include <stdio.h>
1671 #include <errno.h>
1672 #include <time.h>
1673
1674 #ifdef HAVE_SYS_TIME_H
1675 #include <sys/time.h>
1676 #endif
1677
1678 int main() {
1679         struct timespec ts1, ts2;
1680         int code;
1681         ts1.tv_sec  = 0;
1682         ts1.tv_nsec = 750000000;
1683         ts2.tv_sec  = 0;
1684         ts2.tv_nsec = 0;
1685         errno = 0;
1686         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1687         ${cf_cv_main_return:-return}(code != 0);
1688 }
1689 ],
1690         [cf_cv_func_nanosleep=yes],
1691         [cf_cv_func_nanosleep=no],
1692         [cf_cv_func_nanosleep=unknown])])
1693
1694 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP)
1695 ])
1696 dnl ---------------------------------------------------------------------------
1697 dnl CF_FUNC_OPENPTY version: 3 updated: 2010/05/29 16:31:02
1698 dnl ---------------
1699 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1700 dnl "util" library as well.
1701 AC_DEFUN([CF_FUNC_OPENPTY],
1702 [
1703 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1704 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1705     cf_save_LIBS="$LIBS"
1706     test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1707     for cf_header in pty.h libutil.h util.h
1708     do
1709     AC_TRY_LINK([
1710 #include <$cf_header>
1711 ],[
1712     int x = openpty((int *)0, (int *)0, (char *)0,
1713                    (struct termios *)0, (struct winsize *)0);
1714 ],[
1715         cf_cv_func_openpty=$cf_header
1716         break
1717 ],[
1718         cf_cv_func_openpty=no
1719 ])
1720     done
1721     LIBS="$cf_save_LIBS"
1722 ])
1723 ])dnl
1724 dnl ---------------------------------------------------------------------------
1725 dnl CF_FUNC_POLL version: 7 updated: 2012/06/09 16:22:17
1726 dnl ------------
1727 dnl See if the poll function really works.  Some platforms have poll(), but
1728 dnl it does not work for terminals or files.
1729 AC_DEFUN([CF_FUNC_POLL],[
1730 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1731 AC_TRY_RUN([
1732 #include <stdlib.h>
1733 #include <stdio.h>
1734 #include <unistd.h>
1735 #include <fcntl.h>
1736 #ifdef HAVE_POLL_H
1737 #include <poll.h>
1738 #else
1739 #include <sys/poll.h>
1740 #endif
1741 int main() {
1742         struct pollfd myfds;
1743         int ret;
1744
1745         /* check for Darwin bug with respect to "devices" */
1746         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
1747         if (myfds.fd < 0)
1748                 myfds.fd = 0;
1749         myfds.events = POLLIN;
1750         myfds.revents = 0;
1751
1752         ret = poll(&myfds, 1, 100);
1753
1754         if (ret < 0 || (myfds.revents & POLLNVAL)) {
1755                 ret = -1;
1756         } else {
1757                 int fd = 0;
1758                 if (!isatty(fd)) {
1759                         fd = open("/dev/tty", 2);       /* O_RDWR */
1760                 }
1761
1762                 if (fd >= 0) {
1763                         /* also check with standard input */
1764                         myfds.fd = fd;
1765                         myfds.events = POLLIN;
1766                         myfds.revents = 0;
1767                         ret = poll(&myfds, 1, 100);
1768                 } else {
1769                         ret = -1;
1770                 }
1771         }
1772         ${cf_cv_main_return:-return}(ret < 0);
1773 }],
1774         [cf_cv_working_poll=yes],
1775         [cf_cv_working_poll=no],
1776         [cf_cv_working_poll=unknown])])
1777 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL)
1778 ])dnl
1779 dnl ---------------------------------------------------------------------------
1780 dnl CF_FUNC_TERMIOS version: 2 updated: 2000/07/22 23:37:24
1781 dnl ---------------
1782 dnl Some old/broken variations define tcgetattr() only as a macro in
1783 dnl termio(s).h
1784 AC_DEFUN([CF_FUNC_TERMIOS],[
1785 AC_REQUIRE([CF_STRUCT_TERMIOS])
1786 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1787 AC_TRY_LINK([
1788 #include <sys/types.h>
1789 #ifdef HAVE_UNISTD_H
1790 #include <unistd.h>
1791 #endif
1792 #ifdef HAVE_TERMIOS_H
1793 #include <termios.h>
1794 #define TTY struct termios
1795 #else
1796 #ifdef HAVE_TERMIO_H
1797 #include <termio.h>
1798 #define TTY struct termio
1799 #endif
1800 #endif
1801 ],[
1802 TTY foo;
1803 tcgetattr(1, &foo);],
1804 [cf_cv_have_tcgetattr=yes],
1805 [cf_cv_have_tcgetattr=no])])
1806 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR)
1807 ])dnl
1808 dnl ---------------------------------------------------------------------------
1809 dnl CF_FUNC_VSSCANF version: 3 updated: 2001/12/19 00:50:10
1810 dnl ---------------
1811 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1812 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1813 dnl other functions.
1814 AC_DEFUN([CF_FUNC_VSSCANF],
1815 [
1816 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1817 AC_TRY_LINK([
1818 #include <stdarg.h>
1819 #include <stdio.h>],[
1820         va_list ap;
1821         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1822 AC_TRY_LINK([
1823 #include <stdarg.h>
1824 #include <stdio.h>],[
1825     FILE strbuf;
1826     char *str = "from";
1827
1828     strbuf._flag = _IOREAD;
1829     strbuf._ptr = strbuf._base = (unsigned char *) str;
1830     strbuf._cnt = strlen(str);
1831     strbuf._file = _NFILE;
1832     return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1833 AC_TRY_LINK([
1834 #include <stdarg.h>
1835 #include <stdio.h>],[
1836     FILE strbuf;
1837     char *str = "from";
1838
1839     strbuf._flag = _IOREAD;
1840     strbuf._ptr = strbuf._base = (unsigned char *) str;
1841     strbuf._cnt = strlen(str);
1842     strbuf._file = _NFILE;
1843     return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1844 cf_cv_func_vsscanf=no])])])])
1845
1846 case $cf_cv_func_vsscanf in #(vi
1847 vsscanf) AC_DEFINE(HAVE_VSSCANF);; #(vi
1848 vfscanf) AC_DEFINE(HAVE_VFSCANF);; #(vi
1849 _doscan) AC_DEFINE(HAVE__DOSCAN);;
1850 esac
1851
1852 ])dnl
1853 dnl ---------------------------------------------------------------------------
1854 dnl CF_GCC_ATTRIBUTES version: 14 updated: 2010/10/23 15:52:32
1855 dnl -----------------
1856 dnl Test for availability of useful gcc __attribute__ directives to quiet
1857 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1858 dnl to documentation, unrecognized directives cause older compilers to barf.
1859 AC_DEFUN([CF_GCC_ATTRIBUTES],
1860 [
1861 if test "$GCC" = yes
1862 then
1863 cat > conftest.i <<EOF
1864 #ifndef GCC_PRINTF
1865 #define GCC_PRINTF 0
1866 #endif
1867 #ifndef GCC_SCANF
1868 #define GCC_SCANF 0
1869 #endif
1870 #ifndef GCC_NORETURN
1871 #define GCC_NORETURN /* nothing */
1872 #endif
1873 #ifndef GCC_UNUSED
1874 #define GCC_UNUSED /* nothing */
1875 #endif
1876 EOF
1877 if test "$GCC" = yes
1878 then
1879         AC_CHECKING([for $CC __attribute__ directives])
1880 cat > conftest.$ac_ext <<EOF
1881 #line __oline__ "${as_me:-configure}"
1882 #include "confdefs.h"
1883 #include "conftest.h"
1884 #include "conftest.i"
1885 #if     GCC_PRINTF
1886 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1887 #else
1888 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1889 #endif
1890 #if     GCC_SCANF
1891 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1892 #else
1893 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1894 #endif
1895 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1896 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1897 extern void foo(void) GCC_NORETURN;
1898 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1899 EOF
1900         cf_printf_attribute=no
1901         cf_scanf_attribute=no
1902         for cf_attribute in scanf printf unused noreturn
1903         do
1904                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1905                 cf_directive="__attribute__(($cf_attribute))"
1906                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1907
1908                 case $cf_attribute in #(vi
1909                 printf) #(vi
1910                         cf_printf_attribute=yes
1911                         cat >conftest.h <<EOF
1912 #define GCC_$cf_ATTRIBUTE 1
1913 EOF
1914                         ;;
1915                 scanf) #(vi
1916                         cf_scanf_attribute=yes
1917                         cat >conftest.h <<EOF
1918 #define GCC_$cf_ATTRIBUTE 1
1919 EOF
1920                         ;;
1921                 *) #(vi
1922                         cat >conftest.h <<EOF
1923 #define GCC_$cf_ATTRIBUTE $cf_directive
1924 EOF
1925                         ;;
1926                 esac
1927
1928                 if AC_TRY_EVAL(ac_compile); then
1929                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1930                         cat conftest.h >>confdefs.h
1931                         case $cf_attribute in #(vi
1932                         printf) #(vi
1933                                 if test "$cf_printf_attribute" = no ; then
1934                                         cat >>confdefs.h <<EOF
1935 #define GCC_PRINTFLIKE(fmt,var) /* nothing */
1936 EOF
1937                                 else
1938                                         cat >>confdefs.h <<EOF
1939 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1940 EOF
1941                                 fi
1942                                 ;;
1943                         scanf) #(vi
1944                                 if test "$cf_scanf_attribute" = no ; then
1945                                         cat >>confdefs.h <<EOF
1946 #define GCC_SCANFLIKE(fmt,var) /* nothing */
1947 EOF
1948                                 else
1949                                         cat >>confdefs.h <<EOF
1950 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1951 EOF
1952                                 fi
1953                                 ;;
1954                         esac
1955                 fi
1956         done
1957 else
1958         fgrep define conftest.i >>confdefs.h
1959 fi
1960 rm -rf conftest*
1961 fi
1962 ])dnl
1963 dnl ---------------------------------------------------------------------------
1964 dnl CF_GCC_VERSION version: 5 updated: 2010/04/24 11:02:31
1965 dnl --------------
1966 dnl Find version of gcc
1967 AC_DEFUN([CF_GCC_VERSION],[
1968 AC_REQUIRE([AC_PROG_CC])
1969 GCC_VERSION=none
1970 if test "$GCC" = yes ; then
1971         AC_MSG_CHECKING(version of $CC)
1972         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1973         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1974         AC_MSG_RESULT($GCC_VERSION)
1975 fi
1976 ])dnl
1977 dnl ---------------------------------------------------------------------------
1978 dnl CF_GCC_WARNINGS version: 29 updated: 2012/06/16 14:55:39
1979 dnl ---------------
1980 dnl Check if the compiler supports useful warning options.  There's a few that
1981 dnl we don't use, simply because they're too noisy:
1982 dnl
1983 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1984 dnl     -Wredundant-decls (system headers make this too noisy)
1985 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1986 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1987 dnl             is enabled for ncurses using "--enable-const".
1988 dnl     -pedantic
1989 dnl
1990 dnl Parameter:
1991 dnl     $1 is an optional list of gcc warning flags that a particular
1992 dnl             application might want to use, e.g., "no-unused" for
1993 dnl             -Wno-unused
1994 dnl Special:
1995 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1996 dnl
1997 AC_DEFUN([CF_GCC_WARNINGS],
1998 [
1999 AC_REQUIRE([CF_GCC_VERSION])
2000 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2001 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2002
2003 cat > conftest.$ac_ext <<EOF
2004 #line __oline__ "${as_me:-configure}"
2005 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2006 EOF
2007
2008 if test "$INTEL_COMPILER" = yes
2009 then
2010 # The "-wdXXX" options suppress warnings:
2011 # remark #1419: external declaration in primary source file
2012 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2013 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2014 # remark #193: zero used for undefined preprocessing identifier
2015 # remark #593: variable "curs_sb_left_arrow" was set but never used
2016 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2017 # remark #869: parameter "tw" was never referenced
2018 # remark #981: operands are evaluated in unspecified order
2019 # warning #279: controlling expression is constant
2020
2021         AC_CHECKING([for $CC warning options])
2022         cf_save_CFLAGS="$CFLAGS"
2023         EXTRA_CFLAGS="-Wall"
2024         for cf_opt in \
2025                 wd1419 \
2026                 wd1683 \
2027                 wd1684 \
2028                 wd193 \
2029                 wd593 \
2030                 wd279 \
2031                 wd810 \
2032                 wd869 \
2033                 wd981
2034         do
2035                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2036                 if AC_TRY_EVAL(ac_compile); then
2037                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2038                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2039                 fi
2040         done
2041         CFLAGS="$cf_save_CFLAGS"
2042
2043 elif test "$GCC" = yes
2044 then
2045         AC_CHECKING([for $CC warning options])
2046         cf_save_CFLAGS="$CFLAGS"
2047         EXTRA_CFLAGS=
2048         cf_warn_CONST=""
2049         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2050         for cf_opt in W Wall \
2051                 Wbad-function-cast \
2052                 Wcast-align \
2053                 Wcast-qual \
2054                 Winline \
2055                 Wmissing-declarations \
2056                 Wmissing-prototypes \
2057                 Wnested-externs \
2058                 Wpointer-arith \
2059                 Wshadow \
2060                 Wstrict-prototypes \
2061                 Wundef $cf_warn_CONST $1
2062         do
2063                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2064                 if AC_TRY_EVAL(ac_compile); then
2065                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2066                         case $cf_opt in #(vi
2067                         Wcast-qual) #(vi
2068                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2069                                 ;;
2070                         Winline) #(vi
2071                                 case $GCC_VERSION in
2072                                 [[34]].*)
2073                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2074                                         continue;;
2075                                 esac
2076                                 ;;
2077                         Wpointer-arith) #(vi
2078                                 case $GCC_VERSION in
2079                                 [[12]].*)
2080                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2081                                         continue;;
2082                                 esac
2083                                 ;;
2084                         esac
2085                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2086                 fi
2087         done
2088         CFLAGS="$cf_save_CFLAGS"
2089 fi
2090 rm -rf conftest*
2091
2092 AC_SUBST(EXTRA_CFLAGS)
2093 ])dnl
2094 dnl ---------------------------------------------------------------------------
2095 dnl CF_GETOPT_HEADER version: 4 updated: 2009/08/31 20:07:52
2096 dnl ----------------
2097 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2098 dnl unistd.h or (nonstandard) in getopt.h
2099 AC_DEFUN([CF_GETOPT_HEADER],
2100 [
2101 AC_HAVE_HEADERS(unistd.h getopt.h)
2102 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2103 cf_cv_getopt_header=none
2104 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2105 do
2106 AC_TRY_COMPILE([
2107 #include <$cf_header>],
2108 [int x = optind; char *y = optarg],
2109 [cf_cv_getopt_header=$cf_header
2110  break])
2111 done
2112 ])
2113 if test $cf_cv_getopt_header != none ; then
2114         AC_DEFINE(HAVE_GETOPT_HEADER)
2115 fi
2116 ])dnl
2117 dnl ---------------------------------------------------------------------------
2118 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
2119 dnl ----------------
2120 AC_DEFUN([CF_GNAT_GENERICS],
2121 [
2122 AC_REQUIRE([CF_GNAT_VERSION])
2123
2124 AC_MSG_CHECKING(if GNAT supports generics)
2125 case $cf_gnat_version in #(vi
2126 3.[[1-9]]*|[[4-9]].*) #(vi
2127         cf_gnat_generics=yes
2128         ;;
2129 *)
2130         cf_gnat_generics=no
2131         ;;
2132 esac
2133 AC_MSG_RESULT($cf_gnat_generics)
2134
2135 if test "$cf_gnat_generics" = yes
2136 then
2137         cf_compile_generics=generics
2138         cf_generic_objects="\${GENOBJS}"
2139 else
2140         cf_compile_generics=
2141         cf_generic_objects=
2142 fi
2143
2144 AC_SUBST(cf_compile_generics)
2145 AC_SUBST(cf_generic_objects)
2146 ])dnl
2147 dnl ---------------------------------------------------------------------------
2148 dnl CF_GNAT_PRAGMA_UNREF version: 1 updated: 2010/06/19 15:22:18
2149 dnl --------------------
2150 dnl Check if the gnat pragma "Unreferenced" works.
2151 AC_DEFUN([CF_GNAT_PRAGMA_UNREF],[
2152 AC_CACHE_CHECK(if GNAT pragma Unreferenced works,cf_cv_pragma_unreferenced,[
2153 CF_GNAT_TRY_LINK([procedure conftest;],
2154 [with Text_IO;
2155 with GNAT.OS_Lib;
2156 procedure conftest is
2157    test : Integer;
2158    pragma Unreferenced (test);
2159 begin
2160    test := 1;
2161    Text_IO.Put ("Hello World");
2162    Text_IO.New_Line;
2163    GNAT.OS_Lib.OS_Exit (0);
2164 end conftest;],
2165         [cf_cv_pragma_unreferenced=yes],
2166         [cf_cv_pragma_unreferenced=no])])
2167
2168 # if the pragma is supported, use it (needed in the Trace code).
2169 if test $cf_cv_pragma_unreferenced = yes ; then
2170         PRAGMA_UNREF=TRUE
2171 else
2172         PRAGMA_UNREF=FALSE
2173 fi
2174 AC_SUBST(PRAGMA_UNREF)
2175 ])dnl
2176 dnl ---------------------------------------------------------------------------
2177 dnl CF_GNAT_PROJECTS version: 2 updated: 2011/03/23 20:24:41
2178 dnl ----------------
2179 dnl GNAT projects are configured with ".gpr" project files.
2180 dnl GNAT libraries are a further development, using the project feature.
2181 AC_DEFUN([CF_GNAT_PROJECTS],
2182 [
2183 AC_REQUIRE([CF_GNAT_VERSION])
2184
2185 cf_gnat_libraries=no
2186 cf_gnat_projects=no
2187
2188 AC_MSG_CHECKING(if GNAT supports project files)
2189 case $cf_gnat_version in #(vi
2190 3.[[0-9]]*) #(vi
2191         ;;
2192 *)
2193         case $cf_cv_system_name in #(vi
2194         cygwin*) #(vi
2195                 ;;
2196         *)
2197                 mkdir conftest.src conftest.bin conftest.lib
2198                 cd conftest.src
2199                 rm -rf conftest* *~conftest*
2200                 cat >>library.gpr <<CF_EOF
2201 project Library is
2202   Kind := External ("LIB_KIND");
2203   for Library_Name use "ConfTest";
2204   for Object_Dir use ".";
2205   for Library_ALI_Dir use External("LIBRARY_DIR");
2206   for Library_Version use External ("SONAME");
2207   for Library_Kind use Kind;
2208   for Library_Dir use External("BUILD_DIR");
2209   Source_Dir := External ("SOURCE_DIR");
2210   for Source_Dirs use (Source_Dir);
2211   package Compiler is
2212      for Default_Switches ("Ada") use
2213        ("-g",
2214         "-O2",
2215         "-gnatafno",
2216         "-gnatVa",   -- All validity checks
2217         "-gnatwa");  -- Activate all optional errors
2218   end Compiler;
2219 end Library;
2220 CF_EOF
2221                 cat >>confpackage.ads <<CF_EOF
2222 package ConfPackage is
2223    procedure conftest;
2224 end ConfPackage;
2225 CF_EOF
2226                 cat >>confpackage.adb <<CF_EOF
2227 with Text_IO;
2228 package body ConfPackage is
2229    procedure conftest is
2230    begin
2231       Text_IO.Put ("Hello World");
2232       Text_IO.New_Line;
2233    end conftest;
2234 end ConfPackage;
2235 CF_EOF
2236                 if ( $cf_ada_make $ADAFLAGS \
2237                                 -Plibrary.gpr \
2238                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2239                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2240                                 -XSOURCE_DIR=`pwd` \
2241                                 -XSONAME=libConfTest.so.1 \
2242                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2243                         cf_gnat_projects=yes
2244                 fi
2245                 cd ..
2246                 if test -f conftest.lib/confpackage.ali
2247                 then
2248                         cf_gnat_libraries=yes
2249                 fi
2250                 rm -rf conftest* *~conftest*
2251                 ;;
2252         esac
2253         ;;
2254 esac
2255 AC_MSG_RESULT($cf_gnat_projects)
2256
2257 if test $cf_gnat_projects = yes
2258 then
2259         AC_MSG_CHECKING(if GNAT supports libraries)
2260         AC_MSG_RESULT($cf_gnat_libraries)
2261 fi
2262
2263 if test "$cf_gnat_projects" = yes
2264 then
2265         USE_OLD_MAKERULES="#"
2266         USE_GNAT_PROJECTS=""
2267 else
2268         USE_OLD_MAKERULES=""
2269         USE_GNAT_PROJECTS="#"
2270 fi
2271
2272 if test "$cf_gnat_libraries" = yes
2273 then
2274         USE_GNAT_LIBRARIES=""
2275 else
2276         USE_GNAT_LIBRARIES="#"
2277 fi
2278
2279 AC_SUBST(USE_OLD_MAKERULES)
2280 AC_SUBST(USE_GNAT_PROJECTS)
2281 AC_SUBST(USE_GNAT_LIBRARIES)
2282 ])dnl
2283 dnl ---------------------------------------------------------------------------
2284 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2285 dnl --------------
2286 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2287 dnl is noted that gnat may compile a tasking unit even for configurations which
2288 dnl fail at runtime.
2289 AC_DEFUN([CF_GNAT_SIGINT],[
2290 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2291 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2292
2293 package ConfTest is
2294
2295    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2296    pragma Unreserve_All_Interrupts;
2297    pragma Warnings (On);
2298
2299    protected Process is
2300       procedure Stop;
2301       function Continue return Boolean;
2302       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2303    private
2304       Done : Boolean := False;
2305    end Process;
2306
2307 end ConfTest;],
2308 [package body ConfTest is
2309    protected body Process is
2310       procedure Stop is
2311       begin
2312          Done := True;
2313       end Stop;
2314       function Continue return Boolean is
2315       begin
2316          return not Done;
2317       end Continue;
2318    end Process;
2319 end ConfTest;],
2320         [cf_cv_gnat_sigint=yes],
2321         [cf_cv_gnat_sigint=no])])
2322
2323 if test $cf_cv_gnat_sigint = yes ; then
2324         USE_GNAT_SIGINT=""
2325 else
2326         USE_GNAT_SIGINT="#"
2327 fi
2328 AC_SUBST(USE_GNAT_SIGINT)
2329 ])dnl
2330 dnl ---------------------------------------------------------------------------
2331 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2332 dnl ----------------
2333 dnl Verify that a test program compiles/links with GNAT.
2334 dnl $cf_ada_make is set to the program that compiles/links
2335 dnl $ADAFLAGS may be set to the GNAT flags.
2336 dnl
2337 dnl $1 is the text of the spec
2338 dnl $2 is the text of the body
2339 dnl $3 is the shell command to execute if successful
2340 dnl $4 is the shell command to execute if not successful
2341 AC_DEFUN([CF_GNAT_TRY_LINK],
2342 [
2343 rm -rf conftest* *~conftest*
2344 cat >>conftest.ads <<CF_EOF
2345 $1
2346 CF_EOF
2347 cat >>conftest.adb <<CF_EOF
2348 $2
2349 CF_EOF
2350 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2351 ifelse($3,,      :,[      $3])
2352 ifelse($4,,,[else
2353    $4])
2354 fi
2355 rm -rf conftest* *~conftest*
2356 ])dnl
2357 dnl ---------------------------------------------------------------------------
2358 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2359 dnl ---------------
2360 dnl Verify that a test program compiles and runs with GNAT
2361 dnl $cf_ada_make is set to the program that compiles/links
2362 dnl $ADAFLAGS may be set to the GNAT flags.
2363 dnl
2364 dnl $1 is the text of the spec
2365 dnl $2 is the text of the body
2366 dnl $3 is the shell command to execute if successful
2367 dnl $4 is the shell command to execute if not successful
2368 AC_DEFUN([CF_GNAT_TRY_RUN],
2369 [
2370 rm -rf conftest* *~conftest*
2371 cat >>conftest.ads <<CF_EOF
2372 $1
2373 CF_EOF
2374 cat >>conftest.adb <<CF_EOF
2375 $2
2376 CF_EOF
2377 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2378    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2379 ifelse($3,,      :,[      $3])
2380 ifelse($4,,,[   else
2381       $4])
2382    fi
2383 ifelse($4,,,[else
2384    $4])
2385 fi
2386 rm -rf conftest* *~conftest*
2387 ])dnl
2388 dnl ---------------------------------------------------------------------------
2389 dnl CF_GNAT_VERSION version: 18 updated: 2012/01/21 19:28:10
2390 dnl ---------------
2391 dnl Verify version of GNAT.
2392 AC_DEFUN([CF_GNAT_VERSION],
2393 [
2394 AC_MSG_CHECKING(for gnat version)
2395 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2396         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2397     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2398 AC_MSG_RESULT($cf_gnat_version)
2399
2400 case $cf_gnat_version in #(vi
2401 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]]) #(vi
2402         cf_cv_prog_gnat_correct=yes
2403         ;;
2404 *)
2405         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2406         cf_cv_prog_gnat_correct=no
2407         ;;
2408 esac
2409 ])
2410 dnl ---------------------------------------------------------------------------
2411 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2412 dnl -------------
2413 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2414 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2415 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2416 dnl since it is interwoven with GNU extensions.
2417 dnl
2418 dnl Well, yes we could work around it...
2419 AC_DEFUN([CF_GNU_SOURCE],
2420 [
2421 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2422 AC_TRY_COMPILE([#include <sys/types.h>],[
2423 #ifndef _XOPEN_SOURCE
2424 make an error
2425 #endif],
2426         [cf_cv_gnu_source=no],
2427         [cf_save="$CPPFLAGS"
2428          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2429          AC_TRY_COMPILE([#include <sys/types.h>],[
2430 #ifdef _XOPEN_SOURCE
2431 make an error
2432 #endif],
2433         [cf_cv_gnu_source=no],
2434         [cf_cv_gnu_source=yes])
2435         CPPFLAGS="$cf_save"
2436         ])
2437 ])
2438 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2439 ])dnl
2440 dnl ---------------------------------------------------------------------------
2441 dnl CF_GPP_LIBRARY version: 10 updated: 2010/05/29 16:31:02
2442 dnl --------------
2443 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2444 dnl problem :-).  If we have the compiler but no library, we'll be able to
2445 dnl configure, but won't be able to build the c++ demo program.
2446 AC_DEFUN([CF_GPP_LIBRARY],
2447 [
2448 cf_cxx_library=unknown
2449 case $cf_cv_system_name in #(vi
2450 os2*) #(vi
2451         cf_gpp_libname=gpp
2452         ;;
2453 *)
2454         cf_gpp_libname=g++
2455         ;;
2456 esac
2457 if test "$GXX" = yes; then
2458         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2459         cf_save="$LIBS"
2460         CF_ADD_LIB($cf_gpp_libname)
2461         AC_TRY_LINK([
2462 #include <$cf_gpp_libname/builtin.h>
2463         ],
2464         [two_arg_error_handler_t foo2 = lib_error_handler],
2465         [cf_cxx_library=yes
2466          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2467          if test "$cf_gpp_libname" = cpp ; then
2468             AC_DEFINE(HAVE_GPP_BUILTIN_H)
2469          else
2470             AC_DEFINE(HAVE_GXX_BUILTIN_H)
2471          fi],
2472         [AC_TRY_LINK([
2473 #include <builtin.h>
2474         ],
2475         [two_arg_error_handler_t foo2 = lib_error_handler],
2476         [cf_cxx_library=yes
2477          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2478          AC_DEFINE(HAVE_BUILTIN_H)],
2479         [cf_cxx_library=no])])
2480         LIBS="$cf_save"
2481         AC_MSG_RESULT($cf_cxx_library)
2482 fi
2483 ])dnl
2484 dnl ---------------------------------------------------------------------------
2485 dnl CF_GXX_VERSION version: 7 updated: 2012/06/16 14:55:39
2486 dnl --------------
2487 dnl Check for version of g++
2488 AC_DEFUN([CF_GXX_VERSION],[
2489 AC_REQUIRE([AC_PROG_CPP])
2490 GXX_VERSION=none
2491 if test "$GXX" = yes; then
2492         AC_MSG_CHECKING(version of ${CXX:-g++})
2493         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2494         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2495         AC_MSG_RESULT($GXX_VERSION)
2496 fi
2497 ])dnl
2498 dnl ---------------------------------------------------------------------------
2499 dnl CF_GXX_WARNINGS version: 7 updated: 2012/06/16 14:55:39
2500 dnl ---------------
2501 dnl Check if the compiler supports useful warning options.
2502 dnl
2503 dnl Most of gcc's options apply to g++, except:
2504 dnl     -Wbad-function-cast
2505 dnl     -Wmissing-declarations
2506 dnl     -Wnested-externs
2507 dnl
2508 dnl Omit a few (for now):
2509 dnl     -Winline
2510 dnl
2511 dnl Parameter:
2512 dnl     $1 is an optional list of g++ warning flags that a particular
2513 dnl             application might want to use, e.g., "no-unused" for
2514 dnl             -Wno-unused
2515 dnl Special:
2516 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2517 dnl
2518 AC_DEFUN([CF_GXX_WARNINGS],
2519 [
2520
2521 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2522 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2523
2524 AC_REQUIRE([CF_GXX_VERSION])
2525
2526 AC_LANG_SAVE
2527 AC_LANG_CPLUSPLUS
2528
2529 cat > conftest.$ac_ext <<EOF
2530 #line __oline__ "configure"
2531 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2532 EOF
2533
2534 if test "$INTEL_CPLUSPLUS" = yes
2535 then
2536 # The "-wdXXX" options suppress warnings:
2537 # remark #1419: external declaration in primary source file
2538 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2539 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2540 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2541 # remark #193: zero used for undefined preprocessing identifier
2542 # remark #593: variable "curs_sb_left_arrow" was set but never used
2543 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2544 # remark #869: parameter "tw" was never referenced
2545 # remark #981: operands are evaluated in unspecified order
2546 # warning #269: invalid format string conversion
2547
2548         AC_CHECKING([for $CC warning options])
2549         cf_save_CXXFLAGS="$CXXFLAGS"
2550         EXTRA_CXXFLAGS="-Wall"
2551         for cf_opt in \
2552                 wd1419 \
2553                 wd1682 \
2554                 wd1683 \
2555                 wd1684 \
2556                 wd193 \
2557                 wd279 \
2558                 wd593 \
2559                 wd810 \
2560                 wd869 \
2561                 wd981
2562         do
2563                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2564                 if AC_TRY_EVAL(ac_compile); then
2565                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2566                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2567                 fi
2568         done
2569         CXXFLAGS="$cf_save_CXXFLAGS"
2570
2571 elif test "$GXX" = yes
2572 then
2573         AC_CHECKING([for $CXX warning options])
2574         cf_save_CXXFLAGS="$CXXFLAGS"
2575         EXTRA_CXXFLAGS="-W -Wall"
2576         cf_gxx_extra_warnings=""
2577         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2578         case "$GCC_VERSION" in
2579         [[1-2]].*)
2580                 ;;
2581         *)
2582                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2583                 ;;
2584         esac
2585         for cf_opt in \
2586                 Wabi \
2587                 fabi-version=0 \
2588                 Woverloaded-virtual \
2589                 Wsign-promo \
2590                 Wsynth \
2591                 Wold-style-cast \
2592                 Wcast-align \
2593                 Wcast-qual \
2594                 Wmissing-prototypes \
2595                 Wpointer-arith \
2596                 Wshadow \
2597                 Wstrict-prototypes \
2598                 Wundef $cf_gxx_extra_warnings $1
2599         do
2600                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2601                 if AC_TRY_EVAL(ac_compile); then
2602                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2603                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2604                 else
2605                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2606                 fi
2607         done
2608         CXXFLAGS="$cf_save_CXXFLAGS"
2609 fi
2610
2611 rm -rf conftest*
2612 AC_LANG_RESTORE
2613 AC_SUBST(EXTRA_CXXFLAGS)
2614 ])dnl
2615 dnl ---------------------------------------------------------------------------
2616 dnl CF_HASHED_DB version: 4 updated: 2010/05/29 16:31:02
2617 dnl ------------
2618 dnl Look for an instance of the Berkeley hashed database.
2619 dnl
2620 dnl $1 = optional parameter, to specify install-prefix for the database.
2621 AC_DEFUN([CF_HASHED_DB],
2622 [
2623 ifelse([$1],,,[
2624 case $1 in #(vi
2625 yes|*able*) #(vi
2626     ;;
2627 *)
2628     if test -d "$1" ; then
2629         CF_ADD_INCDIR($1/include)
2630         CF_ADD_LIBDIR($1/lib)
2631     fi
2632 esac
2633 ])
2634 AC_CHECK_HEADER(db.h,[
2635 CF_HASHED_DB_VERSION
2636 if test "$cf_cv_hashed_db_version" = unknown ; then
2637         AC_MSG_ERROR(Cannot determine version of db)
2638 else
2639         CF_HASHED_DB_LIBS
2640         if test "$cf_cv_hashed_db_libs" = unknown ; then
2641                 AC_MSG_ERROR(Cannot determine library for db)
2642         elif test "$cf_cv_hashed_db_libs" != default ; then
2643                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2644         fi
2645 fi
2646 ],[
2647         AC_MSG_ERROR(Cannot find db.h)
2648 ])
2649 ])dnl
2650 dnl ---------------------------------------------------------------------------
2651 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2652 dnl -----------------
2653 dnl Given that we have the header and version for hashed database, find the
2654 dnl library information.
2655 AC_DEFUN([CF_HASHED_DB_LIBS],
2656 [
2657 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2658 cf_cv_hashed_db_libs=unknown
2659 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2660 do
2661         cf_save_libs="$LIBS"
2662         if test -n "$cf_db_libs"; then
2663                 CF_ADD_LIB($cf_db_libs)
2664         fi
2665         CF_MSG_LOG(checking for library "$cf_db_libs")
2666         AC_TRY_LINK([
2667 $ac_includes_default
2668 #include <db.h>
2669 ],[
2670         char *path = "/tmp/foo";
2671 #ifdef DB_VERSION_MAJOR
2672 #if DB_VERSION_MAJOR >= 4
2673         DB *result = 0;
2674         db_create(&result, NULL, 0);
2675         result->open(result,
2676                 NULL,
2677                 path,
2678                 path,
2679                 DB_HASH,
2680                 DB_CREATE,
2681                 0644);
2682 #elif DB_VERSION_MAJOR >= 3
2683         DB *result = 0;
2684         db_create(&result, NULL, 0);
2685         result->open(result,
2686                 path,
2687                 path,
2688                 DB_HASH,
2689                 DB_CREATE,
2690                 0644);
2691 #elif DB_VERSION_MAJOR >= 2
2692         DB *result = 0;
2693         db_open(path,
2694                 DB_HASH,
2695                 DB_CREATE,
2696                 0644,
2697                 (DB_ENV *) 0,
2698                 (DB_INFO *) 0,
2699                 &result);
2700 #endif /* DB_VERSION_MAJOR */
2701 #else
2702         DB *result = dbopen(path,
2703                      2,
2704                      0644,
2705                      DB_HASH,
2706                      0);
2707 #endif
2708         ${cf_cv_main_return:-return}(result != 0)
2709 ],[
2710         if test -n "$cf_db_libs" ; then
2711                 cf_cv_hashed_db_libs=$cf_db_libs
2712         else
2713                 cf_cv_hashed_db_libs=default
2714         fi
2715         LIBS="$cf_save_libs"
2716         break
2717 ])
2718         LIBS="$cf_save_libs"
2719 done
2720 ])
2721 ])dnl
2722 dnl ---------------------------------------------------------------------------
2723 dnl CF_HASHED_DB_VERSION version: 3 updated: 2007/12/01 15:01:37
2724 dnl --------------------
2725 dnl Given that we have the header file for hashed database, find the version
2726 dnl information.
2727 AC_DEFUN([CF_HASHED_DB_VERSION],
2728 [
2729 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2730 cf_cv_hashed_db_version=unknown
2731
2732 for cf_db_version in 1 2 3 4 5
2733 do
2734         CF_MSG_LOG(checking for db version $cf_db_version)
2735         AC_TRY_COMPILE([
2736 $ac_includes_default
2737 #include <db.h>
2738
2739 #ifdef DB_VERSION_MAJOR
2740         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2741 #if $cf_db_version == DB_VERSION_MAJOR
2742         /* ok */
2743 #else
2744         make an error
2745 #endif
2746 #else
2747 #if $cf_db_version == 1
2748         /* ok: assuming this is DB 1.8.5 */
2749 #else
2750         make an error
2751 #endif
2752 #endif
2753 ],[DBT *foo = 0],[
2754         cf_cv_hashed_db_version=$cf_db_version
2755         break
2756         ])
2757 done
2758 ])
2759 ])dnl
2760 dnl ---------------------------------------------------------------------------
2761 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
2762 dnl --------------
2763 dnl Construct a search-list of directories for a nonstandard header-file
2764 dnl
2765 dnl Parameters
2766 dnl     $1 = the variable to return as result
2767 dnl     $2 = the package name
2768 AC_DEFUN([CF_HEADER_PATH],
2769 [
2770 $1=
2771
2772 # collect the current set of include-directories from compiler flags
2773 cf_header_path_list=""
2774 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2775         for cf_header_path in $CPPFLAGS $CFLAGS
2776         do
2777                 case $cf_header_path in #(vi
2778                 -I*)
2779                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2780                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2781                         cf_header_path_list="$cf_header_path_list [$]$1"
2782                         ;;
2783                 esac
2784         done
2785 fi
2786
2787 # add the variations for the package we are looking for
2788 CF_SUBDIR_PATH($1,$2,include)
2789
2790 test "$includedir" != NONE && \
2791 test "$includedir" != "/usr/include" && \
2792 test -d "$includedir" && {
2793         test -d $includedir &&    $1="[$]$1 $includedir"
2794         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2795 }
2796
2797 test "$oldincludedir" != NONE && \
2798 test "$oldincludedir" != "/usr/include" && \
2799 test -d "$oldincludedir" && {
2800         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2801         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2802 }
2803
2804 $1="[$]$1 $cf_header_path_list"
2805 ])dnl
2806 dnl ---------------------------------------------------------------------------
2807 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2808 dnl ---------------
2809 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2810 AC_DEFUN([CF_HELP_MESSAGE],
2811 [AC_DIVERT_HELP([$1])dnl
2812 ])dnl
2813 dnl ---------------------------------------------------------------------------
2814 dnl CF_INCLUDE_DIRS version: 6 updated: 2009/01/06 19:37:40
2815 dnl ---------------
2816 dnl Construct the list of include-options according to whether we're building
2817 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
2818 dnl with gcc, don't append the includedir if it happens to be /usr/include,
2819 dnl since that usually breaks gcc's shadow-includes.
2820 AC_DEFUN([CF_INCLUDE_DIRS],
2821 [
2822 CPPFLAGS="$CPPFLAGS -I. -I../include"
2823 if test "$srcdir" != "."; then
2824         CPPFLAGS="$CPPFLAGS -I\${srcdir}/../include"
2825 fi
2826 if test "$GCC" != yes; then
2827         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2828 elif test "$includedir" != "/usr/include"; then
2829         if test "$includedir" = '${prefix}/include' ; then
2830                 if test $prefix != /usr ; then
2831                         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2832                 fi
2833         else
2834                 CPPFLAGS="$CPPFLAGS -I\${includedir}"
2835         fi
2836 fi
2837 AC_SUBST(CPPFLAGS)
2838 ])dnl
2839 dnl ---------------------------------------------------------------------------
2840 dnl CF_INTEL_COMPILER version: 4 updated: 2010/05/26 05:38:42
2841 dnl -----------------
2842 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2843 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2844 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2845 dnl
2846 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2847 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2848 dnl the wrappers for gcc and g++ warnings.
2849 dnl
2850 dnl $1 = GCC (default) or GXX
2851 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2852 dnl $3 = CFLAGS (default) or CXXFLAGS
2853 AC_DEFUN([CF_INTEL_COMPILER],[
2854 ifelse([$2],,INTEL_COMPILER,[$2])=no
2855
2856 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2857         case $host_os in
2858         linux*|gnu*)
2859                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2860                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2861                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2862                 AC_TRY_COMPILE([],[
2863 #ifdef __INTEL_COMPILER
2864 #else
2865 make an error
2866 #endif
2867 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2868 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
2869 ],[])
2870                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2871                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2872                 ;;
2873         esac
2874 fi
2875 ])dnl
2876 dnl ---------------------------------------------------------------------------
2877 dnl CF_ISASCII version: 3 updated: 2000/08/12 23:18:52
2878 dnl ----------
2879 dnl Check if we have either a function or macro for 'isascii()'.
2880 AC_DEFUN([CF_ISASCII],
2881 [
2882 AC_MSG_CHECKING(for isascii)
2883 AC_CACHE_VAL(cf_cv_have_isascii,[
2884         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2885         [cf_cv_have_isascii=yes],
2886         [cf_cv_have_isascii=no])
2887 ])dnl
2888 AC_MSG_RESULT($cf_cv_have_isascii)
2889 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII)
2890 ])dnl
2891 dnl ---------------------------------------------------------------------------
2892 dnl CF_LARGEFILE version: 7 updated: 2007/06/02 11:58:50
2893 dnl ------------
2894 dnl Add checks for large file support.
2895 AC_DEFUN([CF_LARGEFILE],[
2896 ifdef([AC_FUNC_FSEEKO],[
2897     AC_SYS_LARGEFILE
2898     if test "$enable_largefile" != no ; then
2899         AC_FUNC_FSEEKO
2900
2901         # Normally we would collect these definitions in the config.h,
2902         # but (like _XOPEN_SOURCE), some environments rely on having these
2903         # defined before any of the system headers are included.  Another
2904         # case comes up with C++, e.g., on AIX the compiler compiles the
2905         # header files by themselves before looking at the body files it is
2906         # told to compile.  For ncurses, those header files do not include
2907         # the config.h
2908         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2909         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2910         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2911
2912         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2913                 AC_TRY_COMPILE([
2914 #include <sys/types.h>
2915 #include <dirent.h>
2916                 ],[
2917                 /* if transitional largefile support is setup, this is true */
2918                 extern struct dirent64 * readdir(DIR *);
2919                 struct dirent64 *x = readdir((DIR *)0);
2920                 struct dirent *y = readdir((DIR *)0);
2921                 int z = x - y;
2922                 ],
2923                 [cf_cv_struct_dirent64=yes],
2924                 [cf_cv_struct_dirent64=no])
2925         ])
2926         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64)
2927     fi
2928 ])
2929 ])
2930 dnl ---------------------------------------------------------------------------
2931 dnl CF_LDFLAGS_STATIC version: 10 updated: 2011/09/24 12:51:48
2932 dnl -----------------
2933 dnl Check for compiler/linker flags used to temporarily force usage of static
2934 dnl libraries.  This depends on the compiler and platform.  Use this to help
2935 dnl ensure that the linker picks up a given library based on its position in
2936 dnl the list of linker options and libraries.
2937 AC_DEFUN([CF_LDFLAGS_STATIC],[
2938
2939 if test "$GCC" = yes ; then
2940         case $cf_cv_system_name in #(
2941         OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)         #( vi
2942                 LDFLAGS_STATIC=
2943                 LDFLAGS_SHARED=
2944                 ;;
2945     *)  #( normally, except when broken
2946         LDFLAGS_STATIC=-static
2947         LDFLAGS_SHARED=-dynamic
2948         ;;
2949     esac
2950 else
2951         case $cf_cv_system_name in #(
2952         aix[[4-7]]*)    #( from ld manpage
2953                 LDFLAGS_STATIC=-bstatic
2954                 LDFLAGS_SHARED=-bdynamic
2955                 ;;
2956         hpux*)          #( from ld manpage for hpux10.20, hpux11.11
2957                 # We could also use just "archive" and "shared".
2958                 LDFLAGS_STATIC=-Wl,-a,archive_shared
2959                 LDFLAGS_SHARED=-Wl,-a,shared_archive
2960                 ;;
2961         irix*)          #( from ld manpage IRIX64
2962                 LDFLAGS_STATIC=-Bstatic
2963                 LDFLAGS_SHARED=-Bdynamic
2964                 ;;
2965         osf[[45]]*)     #( from ld manpage osf4.0d, osf5.1
2966                 # alternative "-oldstyle_liblookup" (not in cc manpage)
2967                 LDFLAGS_STATIC=-noso
2968                 LDFLAGS_SHARED=-so_archive
2969                 ;;
2970         solaris2*)
2971                 LDFLAGS_STATIC=-Bstatic
2972                 LDFLAGS_SHARED=-Bdynamic
2973                 ;;
2974         esac
2975 fi
2976
2977 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
2978 then
2979         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
2980
2981         rm -f libconftest.a
2982         cat >conftest.$ac_ext <<EOF
2983 #line __oline__ "configure"
2984 #include <stdio.h>
2985 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
2986 EOF
2987         if AC_TRY_EVAL(ac_compile) ; then
2988                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
2989                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
2990         fi
2991         rm -f conftest.*
2992
2993         cf_save_LIBS="$LIBS"
2994
2995         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
2996         AC_TRY_LINK([
2997 #line __oline__ "configure"
2998 #include <stdio.h>
2999 int cf_ldflags_static(FILE *fp);
3000 ],[
3001         return cf_ldflags_static(stdin);
3002 ],[
3003         # some linkers simply ignore the -dynamic
3004         case x`file conftest$ac_exeext 2>/dev/null` in #(vi
3005         *static*) # (vi
3006                 cf_ldflags_static=no
3007                 ;;
3008         *)
3009                 cf_ldflags_static=yes
3010                 ;;
3011         esac
3012 ],[cf_ldflags_static=no])
3013
3014         rm -f libconftest.*
3015         LIBS="$cf_save_LIBS"
3016
3017         AC_MSG_RESULT($cf_ldflags_static)
3018
3019         if test $cf_ldflags_static != yes
3020         then
3021                 LDFLAGS_STATIC=
3022                 LDFLAGS_SHARED=
3023         fi
3024 else
3025         LDFLAGS_STATIC=
3026         LDFLAGS_SHARED=
3027 fi
3028
3029 AC_SUBST(LDFLAGS_STATIC)
3030 AC_SUBST(LDFLAGS_SHARED)
3031 ])
3032 dnl ---------------------------------------------------------------------------
3033 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
3034 dnl ---------------
3035 dnl For the given system and compiler, find the compiler flags to pass to the
3036 dnl loader to use the "rpath" feature.
3037 AC_DEFUN([CF_LD_RPATH_OPT],
3038 [
3039 AC_REQUIRE([CF_CHECK_CACHE])
3040
3041 LD_RPATH_OPT=
3042 AC_MSG_CHECKING(for an rpath option)
3043 case $cf_cv_system_name in #(vi
3044 irix*) #(vi
3045         if test "$GCC" = yes; then
3046                 LD_RPATH_OPT="-Wl,-rpath,"
3047         else
3048                 LD_RPATH_OPT="-rpath "
3049         fi
3050         ;;
3051 linux*|gnu*|k*bsd*-gnu) #(vi
3052         LD_RPATH_OPT="-Wl,-rpath,"
3053         ;;
3054 openbsd[[2-9]].*|mirbsd*) #(vi
3055         LD_RPATH_OPT="-Wl,-rpath,"
3056         ;;
3057 dragonfly*|freebsd*) #(vi
3058         LD_RPATH_OPT="-rpath "
3059         ;;
3060 netbsd*) #(vi
3061         LD_RPATH_OPT="-Wl,-rpath,"
3062         ;;
3063 osf*|mls+*) #(vi
3064         LD_RPATH_OPT="-rpath "
3065         ;;
3066 solaris2*) #(vi
3067         LD_RPATH_OPT="-R"
3068         ;;
3069 *)
3070         ;;
3071 esac
3072 AC_MSG_RESULT($LD_RPATH_OPT)
3073
3074 case "x$LD_RPATH_OPT" in #(vi
3075 x-R*)
3076         AC_MSG_CHECKING(if we need a space after rpath option)
3077         cf_save_LIBS="$LIBS"
3078         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3079         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3080         LIBS="$cf_save_LIBS"
3081         AC_MSG_RESULT($cf_rpath_space)
3082         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3083         ;;
3084 esac
3085 ])dnl
3086 dnl ---------------------------------------------------------------------------
3087 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
3088 dnl ---------------
3089 dnl Construct a search-list of directories for a nonstandard library-file
3090 dnl
3091 dnl Parameters
3092 dnl     $1 = the variable to return as result
3093 dnl     $2 = the package name
3094 AC_DEFUN([CF_LIBRARY_PATH],
3095 [
3096 $1=
3097 cf_library_path_list=""
3098 if test -n "${LDFLAGS}${LIBS}" ; then
3099         for cf_library_path in $LDFLAGS $LIBS
3100         do
3101                 case $cf_library_path in #(vi
3102                 -L*)
3103                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3104                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3105                         cf_library_path_list="$cf_library_path_list [$]$1"
3106                         ;;
3107                 esac
3108         done
3109 fi
3110
3111 CF_SUBDIR_PATH($1,$2,lib)
3112
3113 $1="$cf_library_path_list [$]$1"
3114 ])dnl
3115 dnl ---------------------------------------------------------------------------
3116 dnl CF_LIB_PREFIX version: 9 updated: 2012/01/21 19:28:10
3117 dnl -------------
3118 dnl Compute the library-prefix for the given host system
3119 dnl $1 = variable to set
3120 define([CF_LIB_PREFIX],
3121 [
3122         case $cf_cv_system_name in #(vi
3123         OS/2*|os2*) #(vi
3124         LIB_PREFIX=''
3125         ;;
3126         *)      LIB_PREFIX='lib'
3127         ;;
3128         esac
3129 ifelse($1,,,[$1=$LIB_PREFIX])
3130         AC_SUBST(LIB_PREFIX)
3131 ])dnl
3132 dnl ---------------------------------------------------------------------------
3133 dnl CF_LIB_RULES version: 65 updated: 2012/06/30 17:25:25
3134 dnl ------------
3135 dnl Append definitions and rules for the given models to the subdirectory
3136 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3137 dnl subdirectory is a library-source directory, modify the LIBS_TO_MAKE list in
3138 dnl the corresponding makefile to list the models that we'll generate.
3139 dnl
3140 dnl For shared libraries, make a list of symbolic links to construct when
3141 dnl generating each library.  The convention used for Linux is the simplest
3142 dnl one:
3143 dnl     lib<name>.so    ->
3144 dnl     lib<name>.so.<major>    ->
3145 dnl     lib<name>.so.<maj>.<minor>
3146 AC_DEFUN([CF_LIB_RULES],
3147 [
3148 cf_prefix=$LIB_PREFIX
3149 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3150
3151 case $cf_cv_shlib_version in #(vi
3152 cygdll|mingw)
3153         TINFO_NAME=$TINFO_ARG_SUFFIX
3154         TINFO_SUFFIX=.dll
3155         ;;
3156 esac
3157
3158 if test -n "$TINFO_SUFFIX" ; then
3159         case $TINFO_SUFFIX in
3160         tw*)
3161                 TINFO_NAME="${TINFO_NAME}tw"
3162                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw//'`
3163                 ;;
3164         t*)
3165                 TINFO_NAME="${TINFO_NAME}t"
3166                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t//'`
3167                 ;;
3168         w*)
3169                 TINFO_NAME="${TINFO_NAME}w"
3170                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w//'`
3171                 ;;
3172         esac
3173 fi
3174
3175 for cf_dir in $SRC_SUBDIRS
3176 do
3177         if test ! -d $srcdir/$cf_dir ; then
3178                 continue
3179         elif test -f $srcdir/$cf_dir/modules; then
3180
3181                 SHARED_LIB=
3182                 LIBS_TO_MAKE=
3183                 for cf_item in $cf_LIST_MODELS
3184                 do
3185                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3186                         if test $cf_item = shared ; then
3187                         if test "$cf_cv_do_symlinks" = yes ; then
3188                                 case "$cf_cv_shlib_version" in #(vi
3189                                 rel) #(vi
3190                                         case "$cf_cv_system_name" in #(vi
3191                                         darwin*)
3192                                         case .${LIB_SUFFIX} in
3193                                         .tw*)
3194                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3195                                                 cf_suffix=tw'.${REL_VERSION}'"$cf_suffix"
3196                                                 ;;
3197                                         .t*)
3198                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3199                                                 cf_suffix=t'.${REL_VERSION}'"$cf_suffix"
3200                                                 ;;
3201                                         .w*)
3202                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3203                                                 cf_suffix=w'.${REL_VERSION}'"$cf_suffix"
3204                                                 ;;
3205                                         *)
3206                                                 cf_suffix='.${REL_VERSION}'"$cf_suffix"
3207                                                 ;;
3208                                         esac
3209                                         ;; #(vi
3210                                         *) cf_suffix="$cf_suffix"'.${REL_VERSION}' ;;
3211                                         esac
3212                                         ;;
3213                                 abi)
3214                                         case "$cf_cv_system_name" in #(vi
3215                                         darwin*)
3216                                         case .${LIB_SUFFIX} in
3217                                         .tw*)
3218                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3219                                                 cf_suffix=tw'.${ABI_VERSION}'"$cf_suffix"
3220                                                 ;;
3221                                         .t*)
3222                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3223                                                 cf_suffix=t'.${ABI_VERSION}'"$cf_suffix"
3224                                                 ;;
3225                                         .w*)
3226                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3227                                                 cf_suffix=w'.${ABI_VERSION}'"$cf_suffix"
3228                                                 ;;
3229                                         *)
3230                                                 cf_suffix='.${ABI_VERSION}'"$cf_suffix"
3231                                                 ;;
3232                                         esac
3233                                         ;; #(vi
3234                                         *) cf_suffix="$cf_suffix"'.${ABI_VERSION}' ;;
3235                                         esac
3236                                         ;;
3237                                 esac
3238                         fi
3239                         # cygwin needs import library, and has unique naming convention
3240                         # use autodetected ${cf_prefix} for import lib and static lib, but
3241                         # use 'cyg' prefix for shared lib.
3242                         case $cf_cv_shlib_version in #(vi
3243                         cygdll) #(vi
3244                                 cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3245                                 LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/cyg${cf_dir}${cf_cygsuf}"
3246                                 continue
3247                                 ;;
3248                         mingw)
3249                                 cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3250                                 LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/lib${cf_dir}${cf_cygsuf}"
3251                                 continue
3252                                 ;;
3253                         esac
3254                         fi
3255                         LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/${cf_prefix}${cf_dir}${cf_suffix}"
3256                 done
3257
3258                 if test $cf_dir = ncurses ; then
3259                         cf_subsets="$LIB_SUBSETS"
3260                         cf_r_parts="$cf_subsets"
3261                         cf_liblist="$LIBS_TO_MAKE"
3262
3263                         while test -n "$cf_r_parts"
3264                         do
3265                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3266                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3267                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3268                                         cf_item=
3269                                         case $cf_l_parts in #(vi
3270                                         *termlib*) #(vi
3271                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3272                                                 ;;
3273                                         *ticlib*)
3274                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3275                                                 ;;
3276                                         *)
3277                                                 break
3278                                                 ;;
3279                                         esac
3280                                         if test -n "$cf_item"; then
3281                                                 LIBS_TO_MAKE="$cf_item $LIBS_TO_MAKE"
3282                                         fi
3283                                 else
3284                                         break
3285                                 fi
3286                         done
3287                 else
3288                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3289                 fi
3290
3291                 sed -e "s%@LIBS_TO_MAKE@%$LIBS_TO_MAKE%" \
3292                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3293                         $cf_dir/Makefile >$cf_dir/Makefile.out
3294                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3295
3296                 $AWK -f $srcdir/mk-0th.awk \
3297                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3298                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3299
3300                 for cf_subset in $cf_subsets
3301                 do
3302                         cf_subdirs=
3303                         for cf_item in $cf_LIST_MODELS
3304                         do
3305                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3306                         CF_UPPER(cf_ITEM,$cf_item)
3307                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3308                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3309
3310                         # Test for case where we build libtinfo with a different name.
3311                         cf_libname=$cf_dir
3312                         if test $cf_dir = ncurses ; then
3313                                 case $cf_subset in
3314                                 *base*)
3315                                         cf_libname=${cf_libname}$LIB_SUFFIX
3316                                         ;;
3317                                 *termlib*)
3318                                         cf_libname=$TINFO_LIB_SUFFIX
3319                                         ;;
3320                                 ticlib*)
3321                                         cf_libname=$TICS_LIB_SUFFIX
3322                                         ;;
3323                                 esac
3324                         else
3325                                 cf_libname=${cf_libname}$LIB_SUFFIX
3326                         fi
3327                         if test -n "${DFT_ARG_SUFFIX}" ; then
3328                                 # undo $LIB_SUFFIX add-on in CF_LIB_SUFFIX
3329                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${LIB_SUFFIX}%%"`
3330                         fi
3331
3332                         # These dependencies really are for development, not
3333                         # builds, but they are useful in porting, too.
3334                         cf_depend="../include/ncurses_cfg.h"
3335                         if test "$srcdir" = "."; then
3336                                 cf_reldir="."
3337                         else
3338                                 cf_reldir="\${srcdir}"
3339                         fi
3340
3341                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3342                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3343                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3344                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3345                         fi
3346
3347                         cf_dir_suffix=
3348                         old_cf_suffix="$cf_suffix"
3349                         if test "$cf_cv_shlib_version_infix" = yes ; then
3350                         if test -n "$LIB_SUFFIX" ; then
3351                                 case $LIB_SUFFIX in
3352                                 tw*)
3353                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
3354                                         cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3355                                         cf_dir_suffix=tw
3356                                         ;;
3357                                 t*)
3358                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
3359                                         cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3360                                         cf_dir_suffix=t
3361                                         ;;
3362                                 w*)
3363                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
3364                                         cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3365                                         cf_dir_suffix=w
3366                                         ;;
3367                                 esac
3368                         fi
3369                         fi
3370
3371                         $AWK -f $srcdir/mk-1st.awk \
3372                                 name=${cf_libname}${cf_dir_suffix} \
3373                                 traces=$LIB_TRACING \
3374                                 MODEL=$cf_ITEM \
3375                                 model=$cf_subdir \
3376                                 prefix=$cf_prefix \
3377                                 suffix=$cf_suffix \
3378                                 subset=$cf_subset \
3379                                 driver=$cf_cv_term_driver \
3380                                 SymLink="$LN_S" \
3381                                 TermlibRoot=$TINFO_NAME \
3382                                 TermlibSuffix=$TINFO_SUFFIX \
3383                                 ShlibVer=$cf_cv_shlib_version \
3384                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3385                                 ReLink=${cf_cv_do_relink:-no} \
3386                                 DoLinks=$cf_cv_do_symlinks \
3387                                 rmSoLocs=$cf_cv_rm_so_locs \
3388                                 ldconfig="$LDCONFIG" \
3389                                 overwrite=$WITH_OVERWRITE \
3390                                 depend="$cf_depend" \
3391                                 host="$host" \
3392                                 libtool_version="$LIBTOOL_VERSION" \
3393                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3394
3395                         cf_suffix="$old_cf_suffix"
3396
3397                         for cf_subdir2 in $cf_subdirs lib
3398                         do
3399                                 test $cf_subdir = $cf_subdir2 && break
3400                         done
3401                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3402                         $AWK -f $srcdir/mk-2nd.awk \
3403                                 name=$cf_dir \
3404                                 traces=$LIB_TRACING \
3405                                 MODEL=$cf_ITEM \
3406                                 model=$cf_subdir \
3407                                 subset=$cf_subset \
3408                                 srcdir=$srcdir \
3409                                 echo=$WITH_ECHO \
3410                                 crenames=$cf_cv_prog_CC_c_o \
3411                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3412                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3413                         cf_subdirs="$cf_subdirs $cf_subdir"
3414                         done
3415                 done
3416         fi
3417
3418         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >>Makefile
3419 done
3420
3421 for cf_dir in $SRC_SUBDIRS
3422 do
3423         if test ! -d $srcdir/$cf_dir ; then
3424                 continue
3425         fi
3426
3427         if test -f $cf_dir/Makefile ; then
3428                 case "$cf_dir" in
3429                 Ada95) #(vi
3430                         echo 'libs \' >> Makefile
3431                         echo 'install.libs \' >> Makefile
3432                         echo 'uninstall.libs ::' >> Makefile
3433                         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >> Makefile
3434                         ;;
3435                 esac
3436         fi
3437
3438         if test -f $srcdir/$cf_dir/modules; then
3439                 echo >> Makefile
3440                 if test -f $srcdir/$cf_dir/headers; then
3441 cat >> Makefile <<CF_EOF
3442 install.includes \\
3443 uninstall.includes \\
3444 CF_EOF
3445                 fi
3446 if test "$cf_dir" != "c++" ; then
3447 echo 'lint \' >> Makefile
3448 fi
3449 cat >> Makefile <<CF_EOF
3450 libs \\
3451 lintlib \\
3452 install.libs \\
3453 uninstall.libs \\
3454 install.$cf_dir \\
3455 uninstall.$cf_dir ::
3456         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
3457 CF_EOF
3458         elif test -f $srcdir/$cf_dir/headers; then
3459 cat >> Makefile <<CF_EOF
3460
3461 libs \\
3462 install.libs \\
3463 uninstall.libs \\
3464 install.includes \\
3465 uninstall.includes ::
3466         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
3467 CF_EOF
3468 fi
3469 done
3470
3471 cat >> Makefile <<CF_EOF
3472
3473 install.libs uninstall.libs \\
3474 install.data uninstall.data ::
3475 $MAKE_TERMINFO  cd misc && \${MAKE} \${CF_MFLAGS} \[$]@
3476 CF_EOF
3477
3478 if test "x$cf_with_manpages" = xyes; then
3479 cat >> Makefile <<CF_EOF
3480
3481 install.man \\
3482 uninstall.man ::
3483         cd man && \${MAKE} \${CF_MFLAGS} \[$]@
3484 CF_EOF
3485 fi
3486
3487 cat >> Makefile <<CF_EOF
3488
3489 distclean ::
3490         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3491         rm -f headers.sh headers.sed mk_shared_lib.sh
3492         rm -f edit_man.* man_alias.*
3493         rm -rf \${DIRS_TO_MAKE}
3494 CF_EOF
3495
3496 # Special case: tack's manpage lives in its own directory.
3497 if test "x$cf_with_manpages" = xyes; then
3498 if test -d tack ; then
3499 if test -f $srcdir/$tack.h; then
3500 cat >> Makefile <<CF_EOF
3501
3502 install.man \\
3503 uninstall.man ::
3504         cd tack && \${MAKE} \${CF_MFLAGS} \[$]@
3505 CF_EOF
3506 fi
3507 fi
3508 fi
3509
3510 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3511 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3512 dnl anything, and will make it more standardized.  It's awkward to decide this
3513 dnl at configuration because of quoting, so we'll simply make all headers
3514 dnl installed via a script that can do the right thing.
3515
3516 rm -f headers.sed headers.sh
3517
3518 dnl ( generating this script makes the makefiles a little tidier :-)
3519 echo creating headers.sh
3520 cat >headers.sh <<CF_EOF
3521 #! /bin/sh
3522 # This shell script is generated by the 'configure' script.  It is invoked in a
3523 # subdirectory of the build tree.  It generates a sed-script in the parent
3524 # directory that is used to adjust includes for header files that reside in a
3525 # subdirectory of /usr/include, etc.
3526 PRG=""
3527 while test \[$]# != 3
3528 do
3529 PRG="\$PRG \[$]1"; shift
3530 done
3531 DST=\[$]1
3532 REF=\[$]2
3533 SRC=\[$]3
3534 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3535 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3536 echo installing \$SRC in \$DST
3537 CF_EOF
3538
3539 if test $WITH_CURSES_H = yes; then
3540         cat >>headers.sh <<CF_EOF
3541 case \$DST in
3542 /*/include/*)
3543         END=\`basename \$DST\`
3544         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3545         do
3546                 NAME=\`basename \$i\`
3547                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3548         done
3549         ;;
3550 *)
3551         echo "" >> \$TMPSED
3552         ;;
3553 esac
3554 CF_EOF
3555
3556 else
3557         cat >>headers.sh <<CF_EOF
3558 case \$DST in
3559 /*/include/*)
3560         END=\`basename \$DST\`
3561         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3562         do
3563                 NAME=\`basename \$i\`
3564                 if test "\$NAME" = "curses.h"
3565                 then
3566                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3567                         NAME=ncurses.h
3568                 fi
3569                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3570         done
3571         ;;
3572 *)
3573         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3574         ;;
3575 esac
3576 CF_EOF
3577 fi
3578 cat >>headers.sh <<CF_EOF
3579 rm -f \$TMPSRC
3580 sed -f \$TMPSED \$SRC > \$TMPSRC
3581 NAME=\`basename \$SRC\`
3582 CF_EOF
3583 if test $WITH_CURSES_H != yes; then
3584         cat >>headers.sh <<CF_EOF
3585 test "\$NAME" = "curses.h" && NAME=ncurses.h
3586 CF_EOF
3587 fi
3588 cat >>headers.sh <<CF_EOF
3589 # Just in case someone gzip'd manpages, remove the conflicting copy.
3590 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3591
3592 eval \$PRG \$TMPSRC \$DST/\$NAME
3593 rm -f \$TMPSRC \$TMPSED
3594 CF_EOF
3595
3596 chmod 0755 headers.sh
3597
3598 for cf_dir in $SRC_SUBDIRS
3599 do
3600         if test ! -d $srcdir/$cf_dir ; then
3601                 continue
3602         fi
3603
3604         if test -f $srcdir/$cf_dir/headers; then
3605                 $AWK -f $srcdir/mk-hdr.awk \
3606                         subset="$LIB_SUBSETS" \
3607                         compat="$WITH_CURSES_H" \
3608                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3609         fi
3610
3611         if test -f $srcdir/$cf_dir/modules; then
3612                 if test "$cf_dir" != "c++" ; then
3613                         cat >>$cf_dir/Makefile <<"CF_EOF"
3614 depend : ${AUTO_SRC}
3615         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3616
3617 # DO NOT DELETE THIS LINE -- make depend depends on it.
3618 CF_EOF
3619                 fi
3620         fi
3621 done
3622 AC_SUBST(LIBS_TO_MAKE)
3623 ])dnl
3624 dnl ---------------------------------------------------------------------------
3625 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3626 dnl -------------
3627 dnl Find the and soname for the given shared library.  Set the cache variable
3628 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3629 dnl variable to "unknown".
3630 dnl
3631 dnl $1 = headers
3632 dnl $2 = code
3633 dnl $3 = library name
3634 AC_DEFUN([CF_LIB_SONAME],
3635 [
3636 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3637
3638 cf_cv_$3_soname=unknown
3639 if test "$cross_compiling" != yes ; then
3640 cat >conftest.$ac_ext <<CF_EOF
3641 $1
3642 int main()
3643 {
3644 $2
3645         ${cf_cv_main_return:-return}(0);
3646 }
3647 CF_EOF
3648 cf_save_LIBS="$LIBS"
3649         CF_ADD_LIB($3)
3650         if AC_TRY_EVAL(ac_compile) ; then
3651                 if AC_TRY_EVAL(ac_link) ; then
3652                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3653                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3654                 fi
3655         fi
3656 rm -rf conftest*
3657 LIBS="$cf_save_LIBS"
3658 fi
3659 ])
3660 ])
3661 dnl ---------------------------------------------------------------------------
3662 dnl CF_LIB_SUFFIX version: 18 updated: 2012/02/25 15:20:07
3663 dnl -------------
3664 dnl Compute the library file-suffix from the given model name
3665 dnl $1 = model name
3666 dnl $2 = variable to set (the nominal library suffix)
3667 dnl $3 = dependency variable to set (actual filename)
3668 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3669 AC_DEFUN([CF_LIB_SUFFIX],
3670 [
3671         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3672         case $1 in #(vi
3673         libtool) #(vi
3674                 $2='.la'
3675                 $3=[$]$2
3676                 ;;
3677         normal) #(vi
3678                 $2='.a'
3679                 $3=[$]$2
3680                 ;;
3681         debug) #(vi
3682                 $2='_g.a'
3683                 $3=[$]$2
3684                 ;;
3685         profile) #(vi
3686                 $2='_p.a'
3687                 $3=[$]$2
3688                 ;;
3689         shared) #(vi
3690                 case $cf_cv_system_name in
3691                 aix[[5-7]]*) #(vi
3692                         $2='.a'
3693                         $3=[$]$2
3694                         ;;
3695                 cygwin*|mingw*) #(vi
3696                         $2='.dll'
3697                         $3='.dll.a'
3698                         ;;
3699                 darwin*) #(vi
3700                         $2='.dylib'
3701                         $3=[$]$2
3702                         ;;
3703                 hpux*) #(vi
3704                         case $target in
3705                         ia64*) #(vi
3706                                 $2='.so'
3707                                 $3=[$]$2
3708                                 ;;
3709                         *) #(vi
3710                                 $2='.sl'
3711                                 $3=[$]$2
3712                                 ;;
3713                         esac
3714                         ;;
3715                 *)      $2='.so'
3716                         $3=[$]$2
3717                         ;;
3718                 esac
3719         esac
3720         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3721         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
3722 ])dnl
3723 dnl ---------------------------------------------------------------------------
3724 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
3725 dnl -----------
3726 dnl Compute the string to append to -library from the given model name
3727 dnl $1 = model name
3728 dnl $2 = variable to set
3729 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3730 AC_DEFUN([CF_LIB_TYPE],
3731 [
3732         case $1 in
3733         libtool) $2=''   ;;
3734         normal)  $2=''   ;;
3735         debug)   $2='_g' ;;
3736         profile) $2='_p' ;;
3737         shared)  $2=''   ;;
3738         esac
3739         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3740 ])dnl
3741 dnl ---------------------------------------------------------------------------
3742 dnl CF_LINK_DATAONLY version: 9 updated: 2009/01/01 20:21:38
3743 dnl ----------------
3744 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3745 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3746 dnl have to provide wrappers for global tables to ensure they're linked
3747 dnl properly.
3748 AC_DEFUN([CF_LINK_DATAONLY],
3749 [
3750 AC_MSG_CHECKING([if data-only library module links])
3751 AC_CACHE_VAL(cf_cv_link_dataonly,[
3752         rm -f conftest.a
3753         cat >conftest.$ac_ext <<EOF
3754 #line __oline__ "configure"
3755 int     testdata[[3]] = { 123, 456, 789 };
3756 EOF
3757         if AC_TRY_EVAL(ac_compile) ; then
3758                 mv conftest.o data.o && \
3759                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3760         fi
3761         rm -f conftest.$ac_ext data.o
3762         cat >conftest.$ac_ext <<EOF
3763 #line __oline__ "configure"
3764 int     testfunc()
3765 {
3766 #if defined(NeXT)
3767         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3768 #else
3769         extern int testdata[[3]];
3770         return testdata[[0]] == 123
3771            &&  testdata[[1]] == 456
3772            &&  testdata[[2]] == 789;
3773 #endif
3774 }
3775 EOF
3776         if AC_TRY_EVAL(ac_compile); then
3777                 mv conftest.o func.o && \
3778                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3779         fi
3780         rm -f conftest.$ac_ext func.o
3781         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3782         cf_saveLIBS="$LIBS"
3783         LIBS="conftest.a $LIBS"
3784         AC_TRY_RUN([
3785         int main()
3786         {
3787                 extern int testfunc();
3788                 ${cf_cv_main_return:-return} (!testfunc());
3789         }
3790         ],
3791         [cf_cv_link_dataonly=yes],
3792         [cf_cv_link_dataonly=no],
3793         [cf_cv_link_dataonly=unknown])
3794         LIBS="$cf_saveLIBS"
3795         ])
3796 AC_MSG_RESULT($cf_cv_link_dataonly)
3797
3798 if test "$cf_cv_link_dataonly" = no ; then
3799         AC_DEFINE(BROKEN_LINKER)
3800         BROKEN_LINKER=1
3801 fi
3802
3803 ])dnl
3804 dnl ---------------------------------------------------------------------------
3805 dnl CF_LINK_FUNCS version: 7 updated: 2006/12/16 12:33:30
3806 dnl -------------
3807 dnl Most Unix systems have both link and symlink, a few don't have symlink.
3808 dnl A few non-Unix systems implement symlink, but not link.
3809 dnl A few non-systems implement neither (or have nonfunctional versions).
3810 AC_DEFUN([CF_LINK_FUNCS],
3811 [
3812 AC_CHECK_FUNCS( \
3813         remove \
3814         unlink )
3815
3816 if test "$cross_compiling" = yes ; then
3817         AC_CHECK_FUNCS( \
3818                 link \
3819                 symlink )
3820 else
3821         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
3822                 cf_cv_link_funcs=
3823                 for cf_func in link symlink ; do
3824                         AC_TRY_RUN([
3825 #include <sys/types.h>
3826 #include <sys/stat.h>
3827 #ifdef HAVE_UNISTD_H
3828 #include <unistd.h>
3829 #endif
3830 int main()
3831 {
3832         int fail = 0;
3833         char *src = "config.log";
3834         char *dst = "conftest.chk";
3835         struct stat src_sb;
3836         struct stat dst_sb;
3837
3838         stat(src, &src_sb);
3839         fail = ($cf_func("config.log", "conftest.chk") < 0)
3840             || (stat(dst, &dst_sb) < 0)
3841             || (dst_sb.st_mtime != src_sb.st_mtime);
3842 #ifdef HAVE_UNLINK
3843         unlink(dst);
3844 #else
3845         remove(dst);
3846 #endif
3847         ${cf_cv_main_return:-return} (fail);
3848 }
3849                         ],[
3850                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
3851                         eval 'ac_cv_func_'$cf_func'=yes'],[
3852                         eval 'ac_cv_func_'$cf_func'=no'],[
3853                         eval 'ac_cv_func_'$cf_func'=error'])
3854                 done
3855                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
3856         ])
3857         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK)
3858         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK)
3859 fi
3860 ])dnl
3861 dnl ---------------------------------------------------------------------------
3862 dnl CF_MAIN_RETURN version: 1 updated: 2006/12/10 09:51:54
3863 dnl --------------
3864 dnl Check if a return from main to the shell actually returns the same exit
3865 dnl code.  This is true for almost any POSIX environment.
3866 dnl
3867 dnl Some very old environments did not flush stdout, etc., on an exit.  That
3868 dnl would be a useful case to test for also.
3869 AC_DEFUN([CF_MAIN_RETURN],
3870 [
3871 cf_cv_main_return=return
3872 ])dnl
3873 dnl ---------------------------------------------------------------------------
3874 dnl CF_MAKEFLAGS version: 14 updated: 2011/03/31 19:29:46
3875 dnl ------------
3876 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
3877 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
3878 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
3879 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
3880 AC_DEFUN([CF_MAKEFLAGS],
3881 [
3882 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
3883         cf_cv_makeflags=''
3884         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
3885         do
3886                 cat >cf_makeflags.tmp <<CF_EOF
3887 SHELL = /bin/sh
3888 all :
3889         @ echo '.$cf_option'
3890 CF_EOF
3891                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
3892                 case "$cf_result" in
3893                 .*k)
3894                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
3895                         case "$cf_result" in
3896                         .*CC=*) cf_cv_makeflags=
3897                                 ;;
3898                         *)      cf_cv_makeflags=$cf_option
3899                                 ;;
3900                         esac
3901                         break
3902                         ;;
3903                 .-)     ;;
3904                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
3905                         ;;
3906                 esac
3907         done
3908         rm -f cf_makeflags.tmp
3909 ])
3910
3911 AC_SUBST(cf_cv_makeflags)
3912 ])dnl
3913 dnl ---------------------------------------------------------------------------
3914 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
3915 dnl ------------
3916 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
3917 dnl a monocase filesystem.
3918 AC_DEFUN([CF_MAKE_TAGS],[
3919 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
3920
3921 AC_CHECK_PROGS(CTAGS, exctags ctags)
3922 AC_CHECK_PROGS(ETAGS, exetags etags)
3923
3924 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
3925
3926 if test "$cf_cv_mixedcase" = yes ; then
3927         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
3928 else
3929         MAKE_UPPER_TAGS=no
3930 fi
3931
3932 if test "$MAKE_UPPER_TAGS" = yes ; then
3933         MAKE_UPPER_TAGS=
3934 else
3935         MAKE_UPPER_TAGS="#"
3936 fi
3937
3938 if test "$MAKE_LOWER_TAGS" = yes ; then
3939         MAKE_LOWER_TAGS=
3940 else
3941         MAKE_LOWER_TAGS="#"
3942 fi
3943
3944 AC_SUBST(CTAGS)
3945 AC_SUBST(ETAGS)
3946
3947 AC_SUBST(MAKE_UPPER_TAGS)
3948 AC_SUBST(MAKE_LOWER_TAGS)
3949 ])dnl
3950 dnl ---------------------------------------------------------------------------
3951 dnl CF_MANPAGE_FORMAT version: 9 updated: 2010/10/23 16:10:30
3952 dnl -----------------
3953 dnl Option to allow user to override automatic configuration of manpage format.
3954 dnl There are several special cases:
3955 dnl
3956 dnl     gzip - man checks for, can display gzip'd files
3957 dnl     compress - man checks for, can display compressed files
3958 dnl     BSDI - files in the cat-directories are suffixed ".0"
3959 dnl     formatted - installer should format (put files in cat-directory)
3960 dnl     catonly - installer should only format, e.g., for a turnkey system.
3961 dnl
3962 dnl There are other configurations which this macro does not test, e.g., HPUX's
3963 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
3964 dnl convention would not match our use).
3965 AC_DEFUN([CF_MANPAGE_FORMAT],
3966 [
3967 AC_REQUIRE([CF_PATHSEP])
3968 AC_MSG_CHECKING(format of man-pages)
3969
3970 AC_ARG_WITH(manpage-format,
3971         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
3972                           optionally formatted/catonly, e.g., gzip,formatted],
3973         [MANPAGE_FORMAT=$withval],
3974         [MANPAGE_FORMAT=unknown])
3975
3976 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
3977 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
3978
3979 cf_unknown=
3980
3981 case $MANPAGE_FORMAT in
3982 unknown)
3983   if test -z "$MANPATH" ; then
3984     MANPATH="/usr/man:/usr/share/man"
3985   fi
3986
3987   # look for the 'date' man-page (it's most likely to be installed!)
3988   MANPAGE_FORMAT=
3989   cf_preform=no
3990   cf_catonly=yes
3991   cf_example=date
3992
3993   IFS="${IFS:-  }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
3994   for cf_dir in $MANPATH; do
3995     test -z "$cf_dir" && cf_dir=/usr/man
3996     for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
3997     do
3998       cf_test=`echo $cf_name | sed -e 's/*//'`
3999       if test "x$cf_test" = "x$cf_name" ; then
4000
4001         case "$cf_name" in
4002         *.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
4003         *.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
4004         *.0)    MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
4005         *)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
4006         esac
4007
4008         case "$cf_name" in
4009         $cf_dir/man*)
4010           cf_catonly=no
4011           ;;
4012         $cf_dir/cat*)
4013           cf_preform=yes
4014           ;;
4015         esac
4016         break
4017       fi
4018
4019       # if we found a match in either man* or cat*, stop looking
4020       if test -n "$MANPAGE_FORMAT" ; then
4021         cf_found=no
4022         test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
4023         test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
4024         case "$cf_name" in
4025         $cf_dir/cat*)
4026           cf_found=yes
4027           ;;
4028         esac
4029         test $cf_found=yes && break
4030       fi
4031     done
4032     # only check the first directory in $MANPATH where we find manpages
4033     if test -n "$MANPAGE_FORMAT" ; then
4034        break
4035     fi
4036   done
4037   # if we did not find the example, just assume it is normal
4038   test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
4039   IFS="$ac_save_ifs"
4040   ;;
4041 *)
4042   for cf_option in $MANPAGE_FORMAT; do
4043      case $cf_option in #(vi
4044      gzip|compress|BSDI|normal|formatted|catonly)
4045        ;;
4046      *)
4047        cf_unknown="$cf_unknown $cf_option"
4048        ;;
4049      esac
4050   done
4051   ;;
4052 esac
4053
4054 AC_MSG_RESULT($MANPAGE_FORMAT)
4055 if test -n "$cf_unknown" ; then
4056   AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
4057 fi
4058 ])dnl
4059 dnl ---------------------------------------------------------------------------
4060 dnl CF_MANPAGE_RENAMES version: 7 updated: 2005/06/18 18:51:57
4061 dnl ------------------
4062 dnl The Debian people have their own naming convention for manpages.  This
4063 dnl option lets us override the name of the file containing renaming, or
4064 dnl disable it altogether.
4065 AC_DEFUN([CF_MANPAGE_RENAMES],
4066 [
4067 AC_MSG_CHECKING(for manpage renaming)
4068
4069 AC_ARG_WITH(manpage-renames,
4070         [  --with-manpage-renames  specify manpage-renaming],
4071         [MANPAGE_RENAMES=$withval],
4072         [MANPAGE_RENAMES=yes])
4073
4074 case ".$MANPAGE_RENAMES" in #(vi
4075 .no) #(vi
4076   ;;
4077 .|.yes)
4078   # Debian 'man' program?
4079   if test -f /etc/debian_version ; then
4080     MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
4081   else
4082     MANPAGE_RENAMES=no
4083   fi
4084   ;;
4085 esac
4086
4087 if test "$MANPAGE_RENAMES" != no ; then
4088   if test -f $srcdir/man/$MANPAGE_RENAMES ; then
4089     MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
4090   elif test ! -f $MANPAGE_RENAMES ; then
4091     AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
4092   fi
4093
4094   test ! -d man && mkdir man
4095
4096   # Construct a sed-script to perform renaming within man-pages
4097   if test -n "$MANPAGE_RENAMES" ; then
4098     test ! -d man && mkdir man
4099     sh $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
4100   fi
4101 fi
4102
4103 AC_MSG_RESULT($MANPAGE_RENAMES)
4104 AC_SUBST(MANPAGE_RENAMES)
4105 ])dnl
4106 dnl ---------------------------------------------------------------------------
4107 dnl CF_MANPAGE_SYMLINKS version: 5 updated: 2010/07/24 17:12:40
4108 dnl -------------------
4109 dnl Some people expect each tool to make all aliases for manpages in the
4110 dnl man-directory.  This accommodates the older, less-capable implementations
4111 dnl of 'man', and is optional.
4112 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4113 [
4114 AC_MSG_CHECKING(if manpage aliases will be installed)
4115
4116 AC_ARG_WITH(manpage-aliases,
4117         [  --with-manpage-aliases  specify manpage-aliases using .so],
4118         [MANPAGE_ALIASES=$withval],
4119         [MANPAGE_ALIASES=yes])
4120
4121 AC_MSG_RESULT($MANPAGE_ALIASES)
4122
4123 case "x$LN_S" in #(vi
4124 xln*) #(vi
4125         cf_use_symlinks=yes
4126         ;;
4127 *)
4128         cf_use_symlinks=no
4129         ;;
4130 esac
4131
4132 MANPAGE_SYMLINKS=no
4133 if test "$MANPAGE_ALIASES" = yes ; then
4134 AC_MSG_CHECKING(if manpage symlinks should be used)
4135
4136 AC_ARG_WITH(manpage-symlinks,
4137         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
4138         [MANPAGE_SYMLINKS=$withval],
4139         [MANPAGE_SYMLINKS=$cf_use_symlinks])
4140
4141 if test "$$cf_use_symlinks" = no; then
4142 if test "$MANPAGE_SYMLINKS" = yes ; then
4143         AC_MSG_WARN(cannot make symlinks, will use .so files)
4144         MANPAGE_SYMLINKS=no
4145 fi
4146 fi
4147
4148 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4149 fi
4150
4151 ])dnl
4152 dnl ---------------------------------------------------------------------------
4153 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4154 dnl --------------
4155 dnl This option causes manpages to be run through tbl(1) to generate tables
4156 dnl correctly.
4157 AC_DEFUN([CF_MANPAGE_TBL],
4158 [
4159 AC_MSG_CHECKING(for manpage tbl)
4160
4161 AC_ARG_WITH(manpage-tbl,
4162         [  --with-manpage-tbl      specify manpage processing with tbl],
4163         [MANPAGE_TBL=$withval],
4164         [MANPAGE_TBL=no])
4165
4166 AC_MSG_RESULT($MANPAGE_TBL)
4167 ])dnl
4168 dnl ---------------------------------------------------------------------------
4169 dnl CF_MAN_PAGES version: 41 updated: 2012/08/11 19:35:44
4170 dnl ------------
4171 dnl Try to determine if the man-pages on the system are compressed, and if
4172 dnl so, what format is used.  Use this information to construct a script that
4173 dnl will install man-pages.
4174 AC_DEFUN([CF_MAN_PAGES],
4175 [
4176 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4177 CF_MANPAGE_FORMAT
4178 CF_MANPAGE_RENAMES
4179 CF_MANPAGE_SYMLINKS
4180 CF_MANPAGE_TBL
4181
4182   if test "$prefix" = "NONE" ; then
4183      cf_prefix="$ac_default_prefix"
4184   else
4185      cf_prefix="$prefix"
4186   fi
4187
4188   case "$MANPAGE_FORMAT" in # (vi
4189   *catonly*) # (vi
4190     cf_format=yes
4191     cf_inboth=no
4192     ;;
4193   *formatted*) # (vi
4194     cf_format=yes
4195     cf_inboth=yes
4196     ;;
4197   *)
4198     cf_format=no
4199     cf_inboth=no
4200     ;;
4201   esac
4202
4203 test ! -d man && mkdir man
4204
4205 cf_so_strip=
4206 cf_compress=
4207 case "$MANPAGE_FORMAT" in #(vi
4208 *compress*) #(vi
4209         cf_so_strip="Z"
4210         cf_compress=compress
4211   ;;
4212 *gzip*)
4213         cf_so_strip="gz"
4214         cf_compress=gzip
4215   ;;
4216 esac
4217
4218 cf_edit_man=./edit_man.sh
4219 cf_man_alias=`pwd`/man_alias.sed
4220
4221 cat >$cf_edit_man <<CF_EOF
4222 #! /bin/sh
4223 # this script is generated by the configure-script CF_MAN_PAGES macro.
4224
4225 prefix="$cf_prefix"
4226 datarootdir="$datarootdir"
4227 datadir="$datadir"
4228
4229 NCURSES_MAJOR="$NCURSES_MAJOR"
4230 NCURSES_MINOR="$NCURSES_MINOR"
4231 NCURSES_PATCH="$NCURSES_PATCH"
4232
4233 NCURSES_OSPEED="$NCURSES_OSPEED"
4234 TERMINFO="$TERMINFO"
4235
4236 INSTALL="$INSTALL"
4237 INSTALL_DATA="$INSTALL_DATA"
4238
4239 transform="$program_transform_name"
4240
4241 TMP=\${TMPDIR:=/tmp}/man\$\$
4242 trap "rm -f \$TMP" 0 1 2 5 15
4243
4244 form=\[$]1
4245 shift || exit 1
4246
4247 verb=\[$]1
4248 shift || exit 1
4249
4250 mandir=\[$]1
4251 shift || exit 1
4252
4253 srcdir=\[$]1
4254 top_srcdir=\[$]srcdir/..
4255 shift || exit 1
4256
4257 if test "\$form" = normal ; then
4258         if test "$cf_format" = yes ; then
4259         if test "$cf_inboth" = no ; then
4260                 sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4261                 exit $?
4262         fi
4263         fi
4264         cf_subdir=\$mandir/man
4265         cf_tables=$MANPAGE_TBL
4266 else
4267         cf_subdir=\$mandir/cat
4268         cf_tables=yes
4269 fi
4270
4271 # process the list of source-files
4272 for i in \[$]* ; do
4273 case \$i in #(vi
4274 *.orig|*.rej) ;; #(vi
4275 *.[[0-9]]*)
4276         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4277         if test \$verb = installing ; then
4278         if test ! -d \$cf_subdir\${section} ; then
4279                 mkdir -p \$cf_subdir\$section
4280         fi
4281         fi
4282
4283         # replace variables in man page
4284         if test ! -f $cf_man_alias ; then
4285 cat >>$cf_man_alias <<-CF_EOF2
4286                 s,@DATADIR@,\$datadir,g
4287                 s,@TERMINFO@,\$TERMINFO,g
4288                 s,@NCURSES_MAJOR@,\$NCURSES_MAJOR,g
4289                 s,@NCURSES_MINOR@,\$NCURSES_MINOR,g
4290                 s,@NCURSES_PATCH@,\$NCURSES_PATCH,g
4291                 s,@NCURSES_OSPEED@,\$NCURSES_OSPEED,g
4292 CF_EOF
4293         ifelse($1,,,[
4294         for cf_name in $1
4295         do
4296                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4297                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4298 cat >>$cf_edit_man <<-CF_EOF
4299                 s,@$cf_NAME@,$cf_name,g
4300 CF_EOF
4301         done
4302         ])
4303 cat >>$cf_edit_man <<CF_EOF
4304 CF_EOF2
4305                 echo "...made $cf_man_alias"
4306         fi
4307
4308         aliases=
4309         cf_source=\`basename \$i\`
4310         inalias=\$cf_source
4311         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4312         if test ! -f \$inalias ; then
4313                 echo .. skipped \$cf_source
4314                 continue
4315         fi
4316 CF_EOF
4317
4318 if test "$MANPAGE_ALIASES" != no ; then
4319 cat >>$cf_edit_man <<CF_EOF
4320         nCurses=ignore.3x
4321         test $with_curses_h = yes && nCurses=ncurses.3x
4322         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4323 CF_EOF
4324 fi
4325
4326 if test "$MANPAGE_RENAMES" = no ; then
4327 cat >>$cf_edit_man <<CF_EOF
4328         # perform program transformations for section 1 man pages
4329         if test \$section = 1 ; then
4330                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4331         else
4332                 cf_target=\$cf_subdir\${section}/\$cf_source
4333         fi
4334 CF_EOF
4335 else
4336 cat >>$cf_edit_man <<CF_EOF
4337         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4338         if test -z "\$cf_target" ; then
4339                 echo '? missing rename for '\$cf_source
4340                 cf_target="\$cf_source"
4341         fi
4342         cf_target="\$cf_subdir\${section}/\${cf_target}"
4343
4344 CF_EOF
4345 fi
4346
4347 cat >>$cf_edit_man <<CF_EOF
4348         sed     -f $cf_man_alias \\
4349 CF_EOF
4350
4351 if test -f $MANPAGE_RENAMES ; then
4352 cat >>$cf_edit_man <<CF_EOF
4353                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4354 CF_EOF
4355 else
4356 cat >>$cf_edit_man <<CF_EOF
4357                 < \$i >\$TMP
4358 CF_EOF
4359 fi
4360
4361 cat >>$cf_edit_man <<CF_EOF
4362 if test \$cf_tables = yes ; then
4363         tbl \$TMP >\$TMP.out
4364         mv \$TMP.out \$TMP
4365 fi
4366 CF_EOF
4367
4368 if test $with_overwrite != yes ; then
4369 cat >>$cf_edit_man <<CF_EOF
4370         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
4371         mv \$TMP.out \$TMP
4372 CF_EOF
4373 fi
4374
4375 if test $with_curses_h != yes ; then
4376 cat >>$cf_edit_man <<CF_EOF
4377         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4378         mv \$TMP.out \$TMP
4379 CF_EOF
4380 fi
4381
4382 cat >>$cf_edit_man <<CF_EOF
4383         if test \$form = format ; then
4384                 nroff -man \$TMP >\$TMP.out
4385                 mv \$TMP.out \$TMP
4386         fi
4387 CF_EOF
4388
4389 if test -n "$cf_compress" ; then
4390 cat >>$cf_edit_man <<CF_EOF
4391         if test \$verb = installing ; then
4392         if ( $cf_compress -f \$TMP )
4393         then
4394                 mv \$TMP.$cf_so_strip \$TMP
4395         fi
4396         fi
4397         cf_target="\$cf_target.$cf_so_strip"
4398 CF_EOF
4399 fi
4400
4401 case "$MANPAGE_FORMAT" in #(vi
4402 *BSDI*)
4403 cat >>$cf_edit_man <<CF_EOF
4404         if test \$form = format ; then
4405                 # BSDI installs only .0 suffixes in the cat directories
4406                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
4407         fi
4408 CF_EOF
4409   ;;
4410 esac
4411
4412 cat >>$cf_edit_man <<CF_EOF
4413         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
4414         if test \$verb = installing ; then
4415                 echo \$verb \$cf_target
4416                 \$INSTALL_DATA \$TMP \$cf_target
4417                 test -d \$cf_subdir\${section} &&
4418                 test -n "\$aliases" && (
4419                         cd \$cf_subdir\${section} && (
4420                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
4421                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
4422                                 cf_target=\`basename \$cf_target\`
4423                                 for cf_alias in \$aliases
4424                                 do
4425                                         if test \$section = 1 ; then
4426                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4427                                         fi
4428
4429                                         if test "$MANPAGE_SYMLINKS" = yes ; then
4430                                                 if test -f \$cf_alias\${suffix} ; then
4431                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
4432                                                         then
4433                                                                 continue
4434                                                         fi
4435                                                 fi
4436                                                 echo .. \$verb alias \$cf_alias\${suffix}
4437 CF_EOF
4438 case "x$LN_S" in #(vi
4439 *-f) #(vi
4440 cat >>$cf_edit_man <<CF_EOF
4441                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4442 CF_EOF
4443         ;;
4444 *)
4445 cat >>$cf_edit_man <<CF_EOF
4446                                                 rm -f \$cf_alias\${suffix}
4447                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4448 CF_EOF
4449         ;;
4450 esac
4451 cat >>$cf_edit_man <<CF_EOF
4452                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
4453                                                 echo ".so \$cf_source" >\$TMP
4454 CF_EOF
4455 if test -n "$cf_compress" ; then
4456 cat >>$cf_edit_man <<CF_EOF
4457                                                 if test -n "$cf_so_strip" ; then
4458                                                         $cf_compress -f \$TMP
4459                                                         mv \$TMP.$cf_so_strip \$TMP
4460                                                 fi
4461 CF_EOF
4462 fi
4463 cat >>$cf_edit_man <<CF_EOF
4464                                                 echo .. \$verb alias \$cf_alias\${suffix}
4465                                                 rm -f \$cf_alias\${suffix}
4466                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
4467                  &