aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2019,2020 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: aclocal.m4,v 1.935 2020/10/24 23:49:51 tom Exp $
  33 dnl Macros used in NCURSES auto-configuration script.
  34 dnl
  35 dnl These macros are maintained separately from NCURSES.  The copyright on
  36 dnl this file applies to the aggregation of macros and does not affect use of
  37 dnl these macros in other applications.
  38 dnl
  39 dnl See these pages for additional information:
  40 dnl             https://invisible-island.net/autoconf/
  41 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  42 dnl
  43 dnl ---------------------------------------------------------------------------
  44 dnl ---------------------------------------------------------------------------
  45 dnl AM_LANGINFO_CODESET version: 5 updated: 2020/03/10 18:53:47
  46 dnl -------------------
  47 dnl Inserted as requested by gettext 0.10.40
  48 dnl File from /usr/share/aclocal
  49 dnl codeset.m4
  50 dnl ====================
  51 dnl serial AM1
  52 dnl
  53 dnl From Bruno Haible.
  54 AC_DEFUN([AM_LANGINFO_CODESET],
  55 [
  56 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  57         [AC_TRY_LINK([#include <langinfo.h>],
  58         [char* cs = nl_langinfo(CODESET); (void)cs],
  59         am_cv_langinfo_codeset=yes,
  60         am_cv_langinfo_codeset=no)
  61         ])
  62         if test $am_cv_langinfo_codeset = yes; then
  63                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  64                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  65         fi
  66 ])dnl
  67 dnl ---------------------------------------------------------------------------
  68 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
  69 dnl ---------------
  70 dnl Provide configure-script defaults for different ncurses ABIs.
  71 AC_DEFUN([CF_ABI_DEFAULTS],[
  72 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  73 case x$cf_cv_abi_version in
  74 (x[[6789]])
  75         cf_dft_ext_colors=yes
  76         cf_dft_ext_const=yes
  77         cf_dft_ext_mouse=yes
  78         cf_dft_ext_putwin=yes
  79         cf_dft_ext_spfuncs=yes
  80         cf_dft_filter_syms=yes
  81         cf_dft_chtype=uint32_t
  82         cf_dft_mmask_t=uint32_t
  83         cf_dft_interop=yes
  84         cf_dft_tparm_arg=intptr_t
  85         cf_dft_with_lp64=yes
  86         ;;
  87 (*)
  88         cf_dft_ext_colors=no
  89         cf_dft_ext_const=no
  90         cf_dft_ext_mouse=no
  91         cf_dft_ext_putwin=no
  92         cf_dft_ext_spfuncs=no
  93         cf_dft_filter_syms=no
  94         cf_dft_chtype=auto
  95         cf_dft_mmask_t=auto
  96         cf_dft_interop=no
  97         cf_dft_tparm_arg=long
  98         cf_dft_with_lp64=no
  99         ;;
 100 esac
 101 ])dnl
 102 dnl ---------------------------------------------------------------------------
 103 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 104 dnl ------------------
 105 dnl Conditionally generate script according to whether we're using a given autoconf.
 106 dnl
 107 dnl $1 = version to compare against
 108 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 109 dnl $3 = code to use if AC_ACVERSION is older than $1.
 110 define([CF_ACVERSION_CHECK],
 111 [
 112 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 113 ifdef([m4_version_compare],
 114 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 115 [CF_ACVERSION_COMPARE(
 116 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 117 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 118 dnl ---------------------------------------------------------------------------
 119 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 120 dnl --------------------
 121 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 122 dnl                      MAJOR2, MINOR2, TERNARY2,
 123 dnl                      PRINTABLE2, not FOUND, FOUND)
 124 define([CF_ACVERSION_COMPARE],
 125 [ifelse(builtin([eval], [$2 < $5]), 1,
 126 [ifelse([$8], , ,[$8])],
 127 [ifelse([$9], , ,[$9])])])dnl
 128 dnl ---------------------------------------------------------------------------
 129 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 130 dnl -------------------
 131 dnl Construct the list of include-options for the C programs in the Ada95
 132 dnl binding.
 133 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 134 [
 135 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 136 if test "$srcdir" != "."; then
 137         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 138 fi
 139 if test "$GCC" != yes; then
 140         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 141 elif test "$includedir" != "/usr/include"; then
 142         if test "$includedir" = '${prefix}/include' ; then
 143                 if test x$prefix != x/usr ; then
 144                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 145                 fi
 146         else
 147                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 148         fi
 149 fi
 150 AC_SUBST(ACPPFLAGS)
 151 ])dnl
 152 dnl ---------------------------------------------------------------------------
 153 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 154 dnl ---------------
 155 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 156 AC_DEFUN([CF_ADD_ADAFLAGS],[
 157         ADAFLAGS="$ADAFLAGS $1"
 158         AC_SUBST(ADAFLAGS)
 159 ])dnl
 160 dnl ---------------------------------------------------------------------------
 161 dnl CF_ADD_CFLAGS version: 14 updated: 2020/04/04 16:16:13
 162 dnl -------------
 163 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 164 dnl $1 = flags to add
 165 dnl $2 = if given makes this macro verbose.
 166 dnl
 167 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 168 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 169 dnl confused by the quotes (which require backslashes to keep them usable).
 170 AC_DEFUN([CF_ADD_CFLAGS],
 171 [
 172 cf_fix_cppflags=no
 173 cf_new_cflags=
 174 cf_new_cppflags=
 175 cf_new_extra_cppflags=
 176
 177 for cf_add_cflags in $1
 178 do
 179 case $cf_fix_cppflags in
 180 (no)
 181         case $cf_add_cflags in
 182         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 183                 case $cf_add_cflags in
 184                 (-D*)
 185                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 186
 187                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 188                                 && test -z "${cf_tst_cflags}" \
 189                                 && cf_fix_cppflags=yes
 190
 191                         if test $cf_fix_cppflags = yes ; then
 192                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 193                                 continue
 194                         elif test "${cf_tst_cflags}" = "\"'" ; then
 195                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 196                                 continue
 197                         fi
 198                         ;;
 199                 esac
 200                 case "$CPPFLAGS" in
 201                 (*$cf_add_cflags)
 202                         ;;
 203                 (*)
 204                         case $cf_add_cflags in
 205                         (-D*)
 206                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 207                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 208                                 ;;
 209                         esac
 210                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 211                         ;;
 212                 esac
 213                 ;;
 214         (*)
 215                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 216                 ;;
 217         esac
 218         ;;
 219 (yes)
 220         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 221
 222         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 223
 224         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 225                 && test -z "${cf_tst_cflags}" \
 226                 && cf_fix_cppflags=no
 227         ;;
 228 esac
 229 done
 230
 231 if test -n "$cf_new_cflags" ; then
 232         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 233         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 234 fi
 235
 236 if test -n "$cf_new_cppflags" ; then
 237         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 238         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 239 fi
 240
 241 if test -n "$cf_new_extra_cppflags" ; then
 242         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 243         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 244 fi
 245
 246 AC_SUBST(EXTRA_CPPFLAGS)
 247
 248 ])dnl
 249 dnl ---------------------------------------------------------------------------
 250 dnl CF_ADD_CXXFLAGS version: 1 updated: 2020/04/04 16:16:13
 251 dnl ---------------
 252 dnl Copy non-preprocessor flags to $CXXFLAGS, preprocessor flags to $CPPFLAGS
 253 dnl The second parameter if given makes this macro verbose.
 254 dnl
 255 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 256 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 257 dnl confused by the quotes (which require backslashes to keep them usable).
 258 AC_DEFUN([CF_ADD_CXXFLAGS],
 259 [
 260 cf_save_CXXFLAGS="$CFLAGS"
 261 CFLAGS="$CXXFLAGS"
 262 CF_ADD_CFLAGS($1 ifelse($2,,,[,$2]))
 263 CXXFLAGS="$CFLAGS"
 264 CFLAGS="$cf_save_CXXFLAGS"
 265 ])dnl
 266 dnl ---------------------------------------------------------------------------
 267 dnl CF_ADD_INCDIR version: 15 updated: 2018/06/20 20:23:13
 268 dnl -------------
 269 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 270 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 271 dnl but old versions (and some misinstalled ones) need that.  To make things
 272 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 273 dnl the include-path).
 274 AC_DEFUN([CF_ADD_INCDIR],
 275 [
 276 if test -n "$1" ; then
 277   for cf_add_incdir in $1
 278   do
 279         while test $cf_add_incdir != /usr/include
 280         do
 281           if test -d $cf_add_incdir
 282           then
 283                 cf_have_incdir=no
 284                 if test -n "$CFLAGS$CPPFLAGS" ; then
 285                   # a loop is needed to ensure we can add subdirs of existing dirs
 286                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 287                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 288                           cf_have_incdir=yes; break
 289                         fi
 290                   done
 291                 fi
 292
 293                 if test "$cf_have_incdir" = no ; then
 294                   if test "$cf_add_incdir" = /usr/local/include ; then
 295                         if test "$GCC" = yes
 296                         then
 297                           cf_save_CPPFLAGS=$CPPFLAGS
 298                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 299                           AC_TRY_COMPILE([#include <stdio.h>],
 300                                   [printf("Hello")],
 301                                   [],
 302                                   [cf_have_incdir=yes])
 303                           CPPFLAGS=$cf_save_CPPFLAGS
 304                         fi
 305                   fi
 306                 fi
 307
 308                 if test "$cf_have_incdir" = no ; then
 309                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 310                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 311
 312                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 313                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 314                   cf_add_incdir="$cf_top_incdir"
 315                 else
 316                   break
 317                 fi
 318           else
 319                 break
 320           fi
 321         done
 322   done
 323 fi
 324 ])dnl
 325 dnl ---------------------------------------------------------------------------
 326 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 327 dnl ----------
 328 dnl Add a library, used to enforce consistency.
 329 dnl
 330 dnl $1 = library to add, without the "-l"
 331 dnl $2 = variable to update (default $LIBS)
 332 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 333 dnl ---------------------------------------------------------------------------
 334 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 335 dnl -------------
 336 dnl     Adds to the library-path
 337 dnl
 338 dnl     Some machines have trouble with multiple -L options.
 339 dnl
 340 dnl $1 is the (list of) directory(s) to add
 341 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 342 dnl
 343 AC_DEFUN([CF_ADD_LIBDIR],
 344 [
 345 if test -n "$1" ; then
 346         for cf_add_libdir in $1
 347         do
 348                 if test $cf_add_libdir = /usr/lib ; then
 349                         :
 350                 elif test -d $cf_add_libdir
 351                 then
 352                         cf_have_libdir=no
 353                         if test -n "$LDFLAGS$LIBS" ; then
 354                                 # a loop is needed to ensure we can add subdirs of existing dirs
 355                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 356                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 357                                                 cf_have_libdir=yes; break
 358                                         fi
 359                                 done
 360                         fi
 361                         if test "$cf_have_libdir" = no ; then
 362                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 363                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 364                         fi
 365                 fi
 366         done
 367 fi
 368 ])dnl
 369 dnl ---------------------------------------------------------------------------
 370 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
 371 dnl -----------
 372 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 373 dnl prepended to an existing list, since their dependencies are assumed to
 374 dnl already exist in the list.
 375 dnl
 376 dnl $1 = libraries to add, with the "-l", etc.
 377 dnl $2 = variable to update (default $LIBS)
 378 AC_DEFUN([CF_ADD_LIBS],[
 379 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
 380 # reverse order
 381 cf_add_0lib=
 382 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
 383 # filter duplicates
 384 for cf_add_1lib in $cf_add_0lib; do
 385         for cf_add_2lib in $cf_add_libs; do
 386                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
 387                         cf_add_1lib=
 388                         break
 389                 fi
 390         done
 391         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
 392 done
 393 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 394 ])dnl
 395 dnl ---------------------------------------------------------------------------
 396 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 397 dnl ------------------
 398 dnl Append to a search-list for a nonstandard header/lib-file
 399 dnl     $1 = the variable to return as result
 400 dnl     $2 = the package name
 401 dnl     $3 = the subdirectory, e.g., bin, include or lib
 402 dnl $4 = the directory under which we will test for subdirectories
 403 dnl $5 = a directory that we do not want $4 to match
 404 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 405 [
 406 test "x$4" != "x$5" && \
 407 test -d "$4" && \
 408 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 409         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 410         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 411         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 412         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 413         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 414         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 415 }
 416 ])dnl
 417 dnl ---------------------------------------------------------------------------
 418 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 419 dnl --------------
 420 dnl use this macro for appending text without introducing an extra blank at
 421 dnl the beginning
 422 define([CF_APPEND_TEXT],
 423 [
 424         test -n "[$]$1" && $1="[$]$1 "
 425         $1="[$]{$1}$2"
 426 ])dnl
 427 dnl ---------------------------------------------------------------------------
 428 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 429 dnl --------------
 430 dnl Allow user to disable a normally-on option.
 431 AC_DEFUN([CF_ARG_DISABLE],
 432 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 433 dnl ---------------------------------------------------------------------------
 434 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 435 dnl -------------
 436 dnl Allow user to enable a normally-off option.
 437 AC_DEFUN([CF_ARG_ENABLE],
 438 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 439 dnl ---------------------------------------------------------------------------
 440 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 441 dnl -------------
 442 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 443 dnl values.
 444 dnl
 445 dnl Parameters:
 446 dnl $1 = option name
 447 dnl $2 = help-string
 448 dnl $3 = action to perform if option is not default
 449 dnl $4 = action if perform if option is default
 450 dnl $5 = default option value (either 'yes' or 'no')
 451 AC_DEFUN([CF_ARG_OPTION],
 452 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 453         if test "$enableval" != "$5" ; then
 454 ifelse([$3],,[    :]dnl
 455 ,[    $3]) ifelse([$4],,,[
 456         else
 457                 $4])
 458         fi],[enableval=$5 ifelse([$4],,,[
 459         $4
 460 ])dnl
 461 ])])dnl
 462 dnl ---------------------------------------------------------------------------
 463 dnl CF_AR_FLAGS version: 7 updated: 2020/04/04 11:37:29
 464 dnl -----------
 465 dnl Check for suitable "ar" (archiver) options for updating an archive.
 466 dnl
 467 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 468 dnl as well as a workaround for breakage of make's archive rules by the GNU
 469 dnl binutils "ar" program.
 470 AC_DEFUN([CF_AR_FLAGS],[
 471 AC_REQUIRE([CF_PROG_AR])
 472
 473 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 474         case $cf_cv_system_name in
 475         (*-msvc*)
 476                 cf_cv_ar_flags=''
 477                 cat >mk_static_lib.sh <<-EOF
 478                 #!$SHELL
 479                 MSVC_BIN="[$]AR"
 480                 out="\[$]1"
 481                 shift
 482                 exec \[$]MSVC_BIN -out:"\[$]out" \[$]@
 483                 EOF
 484                 chmod +x mk_static_lib.sh
 485                 AR=`pwd`/mk_static_lib.sh
 486                 ;;
 487         (*)
 488                 cf_cv_ar_flags=unknown
 489                 for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 490                 do
 491
 492                         # check if $ARFLAGS already contains this choice
 493                         if test "x$ARFLAGS" != "x" ; then
 494                                 cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 495                                 if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 496                                         cf_cv_ar_flags=
 497                                         break
 498                                 fi
 499                         fi
 500
 501                         rm -f conftest.$ac_cv_objext
 502                         rm -f conftest.a
 503
 504                         cat >conftest.$ac_ext <<EOF
 505 #line __oline__ "configure"
 506 int     testdata[[3]] = { 123, 456, 789 };
 507 EOF
 508                         if AC_TRY_EVAL(ac_compile) ; then
 509                                 echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 510                                 $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 511                                 if test -f conftest.a ; then
 512                                         cf_cv_ar_flags=$cf_ar_flags
 513                                         break
 514                                 fi
 515                         else
 516                                 CF_VERBOSE(cannot compile test-program)
 517                                 break
 518                         fi
 519                 done
 520                 rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 521                 ;;
 522         esac
 523 ])
 524
 525 if test -n "$ARFLAGS" ; then
 526         if test -n "$cf_cv_ar_flags" ; then
 527                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 528         fi
 529 else
 530         ARFLAGS=$cf_cv_ar_flags
 531 fi
 532
 533 AC_SUBST(ARFLAGS)
 534 ])
 535 dnl ---------------------------------------------------------------------------
 536 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 537 dnl -----------------
 538 dnl Check if awk can handle big strings using printf.  Some older versions of
 539 dnl awk choke on large strings passed via "%s".
 540 dnl
 541 dnl $1 = desired string size
 542 dnl $2 = variable to set with result
 543 AC_DEFUN([CF_AWK_BIG_PRINTF],
 544 [
 545         case x$AWK in
 546         (x)
 547                 eval $2=no
 548                 ;;
 549         (*)
 550                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 551                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 552                         eval $2=yes
 553                 else
 554                         eval $2=no
 555                 fi
 556                 ;;
 557         esac
 558 ])dnl
 559 dnl ---------------------------------------------------------------------------
 560 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 561 dnl ------------
 562 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 563 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 564 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 565 dnl
 566 dnl Treat the configuration-variable specially here, since we're directly
 567 dnl substituting its value (i.e., 1/0).
 568 dnl
 569 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 570 AC_DEFUN([CF_BOOL_DECL],
 571 [
 572 AC_MSG_CHECKING(if we should include stdbool.h)
 573
 574 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 575         AC_TRY_COMPILE([],[bool foo = false],
 576                 [cf_cv_header_stdbool_h=0],
 577                 [AC_TRY_COMPILE([
 578 #ifndef __BEOS__
 579 #include <stdbool.h>
 580 #endif
 581 ],[bool foo = false],
 582                         [cf_cv_header_stdbool_h=1],
 583                         [cf_cv_header_stdbool_h=0])])])
 584
 585 if test "$cf_cv_header_stdbool_h" = 1
 586 then    AC_MSG_RESULT(yes)
 587 else    AC_MSG_RESULT(no)
 588 fi
 589
 590 AC_MSG_CHECKING([for builtin bool type])
 591
 592 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 593         AC_TRY_COMPILE([
 594 #include <stdio.h>
 595 #include <sys/types.h>
 596 ],[bool x = false],
 597                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 598                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 599         ])
 600
 601 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 602 then    AC_MSG_RESULT(yes)
 603 else    AC_MSG_RESULT(no)
 604 fi
 605 ])dnl
 606 dnl ---------------------------------------------------------------------------
 607 dnl CF_BOOL_SIZE version: 17 updated: 2020/10/24 19:48:55
 608 dnl ------------
 609 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 610 dnl Don't bother looking for bool.h, since it's been deprecated.
 611 dnl
 612 dnl If the current compiler is C rather than C++, we get the bool definition
 613 dnl from <stdbool.h>.
 614 AC_DEFUN([CF_BOOL_SIZE],
 615 [
 616 AC_CHECK_SIZEOF(bool,,[
 617 #include <stdlib.h>
 618 #include <stdio.h>
 619
 620 #if defined(__cplusplus)
 621
 622 #ifdef HAVE_GXX_BUILTIN_H
 623 #include <g++/builtin.h>
 624 #elif HAVE_GPP_BUILTIN_H
 625 #include <gpp/builtin.h>
 626 #elif HAVE_BUILTIN_H
 627 #include <builtin.h>
 628 #endif
 629
 630 #else
 631
 632 #if $cf_cv_header_stdbool_h
 633 #include <stdbool.h>
 634 #endif
 635
 636 #endif
 637 ])
 638
 639 AC_CACHE_CHECK(for type of bool, cf_cv_type_of_bool,[
 640         rm -f cf_test.out
 641         AC_TRY_RUN([
 642 #include <stdlib.h>
 643 #include <stdio.h>
 644
 645 #if defined(__cplusplus)
 646
 647 #ifdef HAVE_GXX_BUILTIN_H
 648 #include <g++/builtin.h>
 649 #elif HAVE_GPP_BUILTIN_H
 650 #include <gpp/builtin.h>
 651 #elif HAVE_BUILTIN_H
 652 #include <builtin.h>
 653 #endif
 654
 655 #else
 656
 657 #if $cf_cv_header_stdbool_h
 658 #include <stdbool.h>
 659 #endif
 660
 661 #endif
 662
 663 int main(void)
 664 {
 665         FILE *fp = fopen("cf_test.out", "w");
 666         if (fp != 0) {
 667                 bool x = true;
 668                 if ((bool)(-x) >= 0)
 669                         fputs("unsigned ", fp);
 670                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 671                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 672                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 673                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 674                 fclose(fp);
 675         }
 676         ${cf_cv_main_return:-return}(0);
 677 }
 678                 ],
 679                 [cf_cv_type_of_bool=`cat cf_test.out`
 680                  if test -z "$cf_cv_type_of_bool"; then
 681                    cf_cv_type_of_bool=unknown
 682                  fi],
 683                 [cf_cv_type_of_bool=unknown],
 684                 [
 685                 case x$ac_cv_sizeof_bool in
 686                 (x1) cf_cv_type_of_bool="unsigned char";;
 687                 (x2) cf_cv_type_of_bool="unsigned short";;
 688                 (x4) cf_cv_type_of_bool="unsigned int";;
 689                 (x8) cf_cv_type_of_bool="unsigned long";;
 690                 (*)  cf_cv_type_of_bool=unknown;;
 691                 esac
 692                 ])
 693         rm -f cf_test.out
 694 ])
 695
 696 if test "$cf_cv_type_of_bool" = unknown ; then
 697         case .$NCURSES_BOOL in
 698         (.auto|.) NCURSES_BOOL=unsigned;;
 699         esac
 700         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 701         cf_cv_type_of_bool=$NCURSES_BOOL
 702 fi
 703 ])dnl
 704 dnl ---------------------------------------------------------------------------
 705 dnl CF_BUILD_CC version: 8 updated: 2018/01/04 20:31:04
 706 dnl -----------
 707 dnl If we're cross-compiling, allow the user to override the tools and their
 708 dnl options.  The configure script is oriented toward identifying the host
 709 dnl compiler, etc., but we need a build compiler to generate parts of the
 710 dnl source.
 711 dnl
 712 dnl $1 = default for $CPPFLAGS
 713 dnl $2 = default for $LIBS
 714 AC_DEFUN([CF_BUILD_CC],[
 715 CF_ACVERSION_CHECK(2.52,,
 716         [AC_REQUIRE([CF_PROG_EXT])])
 717 if test "$cross_compiling" = yes ; then
 718
 719         # defaults that we might want to override
 720         : ${BUILD_CFLAGS:=''}
 721         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 722         : ${BUILD_LDFLAGS:=''}
 723         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 724         : ${BUILD_EXEEXT:='$x'}
 725         : ${BUILD_OBJEXT:='o'}
 726
 727         AC_ARG_WITH(build-cc,
 728                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 729                 [BUILD_CC="$withval"],
 730                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 731         AC_MSG_CHECKING(for native build C compiler)
 732         AC_MSG_RESULT($BUILD_CC)
 733
 734         AC_MSG_CHECKING(for native build C preprocessor)
 735         AC_ARG_WITH(build-cpp,
 736                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 737                 [BUILD_CPP="$withval"],
 738                 [BUILD_CPP='${BUILD_CC} -E'])
 739         AC_MSG_RESULT($BUILD_CPP)
 740
 741         AC_MSG_CHECKING(for native build C flags)
 742         AC_ARG_WITH(build-cflags,
 743                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 744                 [BUILD_CFLAGS="$withval"])
 745         AC_MSG_RESULT($BUILD_CFLAGS)
 746
 747         AC_MSG_CHECKING(for native build C preprocessor-flags)
 748         AC_ARG_WITH(build-cppflags,
 749                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 750                 [BUILD_CPPFLAGS="$withval"])
 751         AC_MSG_RESULT($BUILD_CPPFLAGS)
 752
 753         AC_MSG_CHECKING(for native build linker-flags)
 754         AC_ARG_WITH(build-ldflags,
 755                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 756                 [BUILD_LDFLAGS="$withval"])
 757         AC_MSG_RESULT($BUILD_LDFLAGS)
 758
 759         AC_MSG_CHECKING(for native build linker-libraries)
 760         AC_ARG_WITH(build-libs,
 761                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 762                 [BUILD_LIBS="$withval"])
 763         AC_MSG_RESULT($BUILD_LIBS)
 764
 765         # this assumes we're on Unix.
 766         BUILD_EXEEXT=
 767         BUILD_OBJEXT=o
 768
 769         : ${BUILD_CC:='${CC}'}
 770
 771         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 772                 AC_MSG_ERROR([Cross-build requires two compilers.
 773 Use --with-build-cc to specify the native compiler.])
 774         fi
 775
 776 else
 777         : ${BUILD_CC:='${CC}'}
 778         : ${BUILD_CPP:='${CPP}'}
 779         : ${BUILD_CFLAGS:='${CFLAGS}'}
 780         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 781         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 782         : ${BUILD_LIBS:='${LIBS}'}
 783         : ${BUILD_EXEEXT:='$x'}
 784         : ${BUILD_OBJEXT:='o'}
 785 fi
 786
 787 AC_SUBST(BUILD_CC)
 788 AC_SUBST(BUILD_CPP)
 789 AC_SUBST(BUILD_CFLAGS)
 790 AC_SUBST(BUILD_CPPFLAGS)
 791 AC_SUBST(BUILD_LDFLAGS)
 792 AC_SUBST(BUILD_LIBS)
 793 AC_SUBST(BUILD_EXEEXT)
 794 AC_SUBST(BUILD_OBJEXT)
 795 ])dnl
 796 dnl ---------------------------------------------------------------------------
 797 dnl CF_CC_ENV_FLAGS version: 9 updated: 2018/07/29 18:03:26
 798 dnl ---------------
 799 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 800 dnl into CC.  This will not help with broken scripts that wrap the compiler
 801 dnl with options, but eliminates a more common category of user confusion.
 802 dnl
 803 dnl In particular, it addresses the problem of being able to run the C
 804 dnl preprocessor in a consistent manner.
 805 dnl
 806 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 807 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 808 dnl outweighs that limitation.
 809 AC_DEFUN([CF_CC_ENV_FLAGS],
 810 [
 811 # This should have been defined by AC_PROG_CC
 812 : ${CC:=cc}
 813
 814 AC_MSG_CHECKING(\$CFLAGS variable)
 815 case "x$CFLAGS" in
 816 (*-[[IUD]]*)
 817         AC_MSG_RESULT(broken)
 818         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 819         cf_flags="$CFLAGS"
 820         CFLAGS=
 821         for cf_arg in $cf_flags
 822         do
 823                 CF_ADD_CFLAGS($cf_arg)
 824         done
 825         ;;
 826 (*)
 827         AC_MSG_RESULT(ok)
 828         ;;
 829 esac
 830
 831 AC_MSG_CHECKING(\$CC variable)
 832 case "$CC" in
 833 (*[[\ \ ]]-*)
 834         AC_MSG_RESULT(broken)
 835         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 836         # humor him...
 837         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 838         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 839         CC="$cf_prog"
 840         for cf_arg in $cf_flags
 841         do
 842                 case "x$cf_arg" in
 843                 (x-[[IUDfgOW]]*)
 844                         CF_ADD_CFLAGS($cf_arg)
 845                         ;;
 846                 (*)
 847                         CC="$CC $cf_arg"
 848                         ;;
 849                 esac
 850         done
 851         CF_VERBOSE(resulting CC: '$CC')
 852         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 853         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 854         ;;
 855 (*)
 856         AC_MSG_RESULT(ok)
 857         ;;
 858 esac
 859 ])dnl
 860 dnl ---------------------------------------------------------------------------
 861 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 862 dnl ---------------
 863 dnl Determine the default configuration into which we'll install ncurses.  This
 864 dnl can be overridden by the user's command-line options.  There's two items to
 865 dnl look for:
 866 dnl     1. the prefix (e.g., /usr)
 867 dnl     2. the header files (e.g., /usr/include/ncurses)
 868 dnl We'll look for a previous installation of ncurses and use the same defaults.
 869 dnl
 870 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 871 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 872 dnl programs from a vendor's.
 873 AC_DEFUN([CF_CFG_DEFAULTS],
 874 [
 875 AC_MSG_CHECKING(for prefix)
 876 if test "x$prefix" = "xNONE" ; then
 877         case "$cf_cv_system_name" in
 878                 # non-vendor systems don't have a conflict
 879         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 880                 prefix=/usr
 881                 ;;
 882         (*)     prefix=$ac_default_prefix
 883                 ;;
 884         esac
 885 fi
 886 AC_MSG_RESULT($prefix)
 887
 888 if test "x$prefix" = "xNONE" ; then
 889 AC_MSG_CHECKING(for default include-directory)
 890 test -n "$verbose" && echo 1>&AC_FD_MSG
 891 for cf_symbol in \
 892         $includedir \
 893         $includedir/ncurses \
 894         $prefix/include \
 895         $prefix/include/ncurses \
 896         /usr/local/include \
 897         /usr/local/include/ncurses \
 898         /usr/include \
 899         /usr/include/ncurses
 900 do
 901         cf_dir=`eval echo $cf_symbol`
 902         if test -f $cf_dir/curses.h ; then
 903         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 904                 includedir="$cf_symbol"
 905                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 906                 break
 907         fi
 908         fi
 909         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 910 done
 911 AC_MSG_RESULT($includedir)
 912 fi
 913 ])dnl
 914 dnl ---------------------------------------------------------------------------
 915 dnl CF_CGETENT version: 6 updated: 2017/01/21 11:06:25
 916 dnl ----------
 917 dnl Check if the terminal-capability database functions are available.  If not,
 918 dnl ncurses has a much-reduced version.
 919 AC_DEFUN([CF_CGETENT],[
 920 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 921 AC_TRY_LINK([
 922 #include <stdlib.h>],[
 923         char temp[128];
 924         char *buf = temp;
 925         char *db_array = temp;
 926         cgetent(&buf, &db_array, "vt100");
 927         cgetcap(buf, "tc", '=');
 928         cgetmatch(buf, "tc");
 929         ],
 930         [cf_cv_cgetent=yes],
 931         [cf_cv_cgetent=no])
 932 ])
 933
 934 if test "$cf_cv_cgetent" = yes
 935 then
 936         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 937 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 938 AC_TRY_LINK([
 939 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
 940 #include <stdlib.h>],[
 941         char temp[128];
 942         char *buf = temp;
 943 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 944         const char *db_array = temp;
 945         cgetent(&buf, &db_array, "vt100");
 946 #endif
 947         cgetcap(buf, "tc", '=');
 948         cgetmatch(buf, "tc");
 949         ],
 950         [cf_cv_cgetent_const=yes],
 951         [cf_cv_cgetent_const=no])
 952 ])
 953         if test "$cf_cv_cgetent_const" = yes
 954         then
 955                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 956         fi
 957 fi
 958 ])dnl
 959 dnl ---------------------------------------------------------------------------
 960 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 961 dnl --------------
 962 dnl Check if we're accidentally using a cache from a different machine.
 963 dnl Derive the system name, as a check for reusing the autoconf cache.
 964 dnl
 965 dnl If we've packaged config.guess and config.sub, run that (since it does a
 966 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 967 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 968 dnl which is useful in cross-compiles.
 969 dnl
 970 dnl Note: we would use $ac_config_sub, but that is one of the places where
 971 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 972 AC_DEFUN([CF_CHECK_CACHE],
 973 [
 974 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 975         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 976         system_name="$host_os"
 977 else
 978         system_name="`(uname -s -r) 2>/dev/null`"
 979         if test -z "$system_name" ; then
 980                 system_name="`(hostname) 2>/dev/null`"
 981         fi
 982 fi
 983 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 984 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 985
 986 test -z "$system_name" && system_name="$cf_cv_system_name"
 987 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 988
 989 if test ".$system_name" != ".$cf_cv_system_name" ; then
 990         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 991         AC_MSG_ERROR("Please remove config.cache and try again.")
 992 fi
 993 ])dnl
 994 dnl ---------------------------------------------------------------------------
 995 dnl CF_CHECK_ENVIRON version: 3 updated: 2010/05/26 16:44:57
 996 dnl ----------------
 997 dnl Check for data that is usually declared in <unistd.h>, e.g., the 'environ'
 998 dnl variable.  Define a DECL_xxx symbol if we must declare it ourselves.
 999 dnl
1000 dnl $1 = the name to check
1001 dnl $2 = the assumed type
1002 AC_DEFUN([CF_CHECK_ENVIRON],
1003 [
1004 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1005     AC_TRY_COMPILE([
1006 #ifdef HAVE_STDLIB_H
1007 #include <stdlib.h>
1008 #endif
1009 #include <unistd.h> ],
1010     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
1011     [cf_cv_dcl_$1=yes],
1012     [cf_cv_dcl_$1=no])
1013 ])
1014
1015 if test "$cf_cv_dcl_$1" = no ; then
1016     CF_UPPER(cf_result,decl_$1)
1017     AC_DEFINE_UNQUOTED($cf_result)
1018 fi
1019
1020 # It's possible (for near-UNIX clones) that the data doesn't exist
1021 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1022 ])dnl
1023 dnl ---------------------------------------------------------------------------
1024 dnl CF_CHECK_ERRNO version: 13 updated: 2020/03/10 18:53:47
1025 dnl --------------
1026 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
1027 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
1028 dnl ourselves.
1029 dnl
1030 dnl $1 = the name to check
1031 dnl $2 = the assumed type
1032 AC_DEFUN([CF_CHECK_ERRNO],
1033 [
1034 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1035         AC_TRY_COMPILE([
1036 #ifdef HAVE_STDLIB_H
1037 #include <stdlib.h>
1038 #endif
1039 #include <stdio.h>
1040 #include <sys/types.h>
1041 #include <errno.h> ],
1042         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1; (void)x,
1043         [cf_cv_dcl_$1=yes],
1044         [cf_cv_dcl_$1=no])
1045 ])
1046
1047 if test "$cf_cv_dcl_$1" = no ; then
1048         CF_UPPER(cf_result,decl_$1)
1049         AC_DEFINE_UNQUOTED($cf_result)
1050 fi
1051
1052 # It's possible (for near-UNIX clones) that the data doesn't exist
1053 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1054 ])dnl
1055 dnl ---------------------------------------------------------------------------
1056 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
1057 dnl --------------------
1058 dnl Check for existence of external data in the current set of libraries.  If
1059 dnl we can modify it, it's real enough.
1060 dnl $1 = the name to check
1061 dnl $2 = its type
1062 AC_DEFUN([CF_CHECK_EXTERN_DATA],
1063 [
1064 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
1065         AC_TRY_LINK([
1066 #undef $1
1067 extern $2 $1;
1068 ],
1069         [$1 = 2],
1070         [cf_cv_have_$1=yes],
1071         [cf_cv_have_$1=no])
1072 ])
1073
1074 if test "$cf_cv_have_$1" = yes ; then
1075         CF_UPPER(cf_result,have_$1)
1076         AC_DEFINE_UNQUOTED($cf_result)
1077 fi
1078
1079 ])dnl
1080 dnl ---------------------------------------------------------------------------
1081 dnl CF_CHECK_FVISIBILITY version: 2 updated: 2020/04/04 16:16:13
1082 dnl --------------------
1083 dnl Check whether the compiler understands -fvisibility=hidden
1084 dnl
1085 dnl $1 = compiler
1086 dnl $2 = compiler-flags variable name
1087 dnl $3 = cache variable to set
1088 AC_DEFUN([CF_CHECK_FVISIBILITY],[
1089 AC_CACHE_CHECK(if $1 -fvisibility=hidden option works,$3,[
1090     cf_save_cflags="[$]$2"
1091     $2="[$]$2 -fvisibility=hidden"
1092     AC_TRY_LINK([
1093 __attribute__ ((visibility("default"))) int somefunc() {return 42;}
1094         ],[
1095         if (somefunc()) return 1;
1096 ],
1097     [$3=yes],
1098     [$3=no])
1099     $2=$cf_save_cflags
1100 ])
1101 ])dnl
1102 dnl ---------------------------------------------------------------------------
1103 dnl CF_CHECK_GETENV version: 1 updated: 2019/06/23 15:28:15
1104 dnl ---------------
1105 dnl Check if repeated getenv calls return the same pointer, e.g., it does not
1106 dnl discard the previous pointer when returning a new one.
1107 AC_DEFUN([CF_CHECK_GETENV],
1108 [
1109 AC_REQUIRE([CF_CHECK_ENVIRON])
1110 AC_CHECK_FUNC( getenv, ,, AC_MSG_ERROR(getenv not found) )
1111 AC_CHECK_FUNCS( putenv setenv strdup )
1112 AC_CACHE_CHECK(if getenv returns consistent values,cf_cv_consistent_getenv,[
1113 AC_TRY_RUN([
1114 #include <stdlib.h>
1115 #include <unistd.h>
1116 #include <stdio.h>
1117 #include <string.h>
1118 #include <sys/types.h>
1119
1120 #if defined(HAVE_ENVIRON) && defined(DECL_ENVIRON) && !defined(environ)
1121 extern char **environ;  /* POSIX, but some systems are not... */
1122 #endif
1123
1124 #if defined(HAVE_STRDUP)
1125 #define str_alloc(s) strdup(s)
1126 #else
1127 #define str_alloc(s) strcpy(malloc(strlen(s) + 1, s))
1128 #endif
1129
1130 static void set_value(const char *name, const char *value)
1131 {
1132 #if defined(HAVE_SETENV)
1133         setenv(name, value, 1);
1134 #elif defined(HAVE_PUTENV)
1135         char buffer[1024];
1136         sprintf(buffer, "%s=%s", name, value);
1137         putenv(str_alloc(buffer));
1138 #else
1139 #error neither putenv/setenv found
1140 #endif
1141 }
1142 int main(void)
1143 {
1144         int pass;
1145         size_t numenv, limit, j;
1146         char **mynames;
1147         char **myvalues;
1148         char **mypointer;
1149         char *equals;
1150         for (numenv = 0; environ[numenv]; ++numenv) ;
1151         limit = numenv + 10;
1152         mynames = (char **) calloc(limit + 1, sizeof(char *));
1153         myvalues = (char **) calloc(limit + 1, sizeof(char *));
1154         mypointer = (char **) calloc(limit + 1, sizeof(char *));
1155 #if defined(HAVE_ENVIRON)
1156         for (j = 0; environ[j]; ++j) {
1157                 mynames[j] = str_alloc(environ[j]);
1158                 equals = strchr(mynames[j], '=');
1159                 if (equals != 0) {
1160                         *equals++ = '\0';
1161                         myvalues[j] = str_alloc(equals);
1162                 } else {
1163                         myvalues[j] = str_alloc("");
1164                 }
1165         }
1166 #endif
1167         for (j = numenv; j < limit; ++j) {
1168                 char name[80];
1169                 char value[80];
1170                 size_t found;
1171                 size_t k = 0;
1172                 do {
1173                         size_t jk;
1174                         found = 0;
1175                         sprintf(name, "TERM%lu", (unsigned long) k);
1176                         for (jk = 0; jk < j; ++jk) {
1177                                 if (!strcmp(name, mynames[jk])) {
1178                                         found = 1;
1179                                         ++k;
1180                                         break;
1181                                 }
1182                         }
1183                 } while (found);
1184                 sprintf(value, "%lu:%p", (unsigned long) k, &mynames[j]);
1185                 set_value(name, value);
1186                 mynames[j] = str_alloc(name);
1187                 myvalues[j] = str_alloc(value);
1188         }
1189         for (pass = 0; pass < 3; ++pass) {
1190                 for (j = 0; j < limit; ++j) {
1191                         char *value = getenv(mynames[j]);
1192                         if (pass) {
1193                                 if (value == 0) {
1194                                         fprintf(stderr, "getenv returned null for %s\n", mynames[j]);
1195                                         ${cf_cv_main_return:-return}(1);
1196                                 } else if (value != mypointer[j]) {
1197                                         fprintf(stderr, "getenv returned different pointer for %s\n", mynames[j]);
1198                                         ${cf_cv_main_return:-return}(1);
1199                                 } else if (strcmp(value, myvalues[j])) {
1200                                         fprintf(stderr, "getenv returned different value for %s\n", mynames[j]);
1201                                         ${cf_cv_main_return:-return}(1);
1202                                 }
1203                         } else {
1204                                 size_t k;
1205                                 mypointer[j] = value;
1206                                 for (k = 0; k < j; ++k) {
1207                                         if (mypointer[j] == mypointer[k]) {
1208                                                 fprintf(stderr, "getenv returned same pointer for %s and %s\n", mynames[j], mynames[k]);
1209                                                 ${cf_cv_main_return:-return}(1);
1210                                         }
1211                                 }
1212                         }
1213                 }
1214         }
1215         ${cf_cv_main_return:-return}(0);
1216 }
1217 ],
1218 [cf_cv_consistent_getenv=yes],
1219 [cf_cv_consistent_getenv=no],
1220 [cf_cv_consistent_getenv=unknown])
1221 ])
1222
1223 if test "x$cf_cv_consistent_getenv" = xno
1224 then
1225         AC_DEFINE(HAVE_CONSISTENT_GETENV,1,[Define to 1 if getenv repeatably returns the same value for a given name])
1226 fi
1227 ])dnl
1228 dnl ---------------------------------------------------------------------------
1229 dnl CF_CHECK_GNAT_VERSION version: 3 updated: 2020/05/23 19:39:36
1230 dnl ---------------------
1231 AC_DEFUN([CF_CHECK_GNAT_VERSION],
1232 [
1233 AC_REQUIRE([CF_GNAT_VERSION])
1234 case $cf_cv_gnat_version in
1235 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
1236         cf_cv_prog_gnat_correct=yes
1237         ;;
1238 (*)
1239         AC_MSG_WARN(Unsupported GNAT version $cf_cv_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1240         cf_cv_prog_gnat_correct=no
1241         ;;
1242 esac
1243 ])
1244 dnl ---------------------------------------------------------------------------
1245 dnl CF_CHECK_GPM_WGETCH version: 3 updated: 2017/01/21 11:06:25
1246 dnl -------------------
1247 dnl Check if GPM is already linked with curses.  If so - and if the linkage
1248 dnl is not "weak" - warn about this because it can create problems linking
1249 dnl applications with ncurses.
1250 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
1251 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
1252
1253 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
1254 cf_cv_check_gpm_wgetch=unknown
1255 if test "$cross_compiling" != yes ; then
1256
1257 cat >conftest.$ac_ext <<CF_EOF
1258 #include <gpm.h>
1259 int main(void)
1260 {
1261         Gpm_Wgetch();
1262         ${cf_cv_main_return:-return}(0);
1263 }
1264 CF_EOF
1265
1266         cf_save_LIBS="$LIBS"
1267         # This only works if we can look at the symbol table.  If a shared
1268         # library is stripped for install, we cannot use that.  So we're forced
1269         # to rely on the static library, noting that some packagers may not
1270         # include it.
1271         LIBS="-static -lgpm -dynamic $LIBS"
1272         if AC_TRY_EVAL(ac_compile) ; then
1273                 if AC_TRY_EVAL(ac_link) ; then
1274                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
1275                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
1276                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
1277                 fi
1278         fi
1279         rm -rf conftest*
1280         LIBS="$cf_save_LIBS"
1281 fi
1282 ])
1283
1284 if test "$cf_cv_check_gpm_wgetch" != yes ; then
1285         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
1286 fi
1287 ])])dnl
1288 dnl ---------------------------------------------------------------------------
1289 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
1290 dnl ------------------------
1291 dnl Show the version of libtool
1292 dnl
1293 dnl Save the version in a cache variable - this is not entirely a good thing,
1294 dnl but the version string from libtool is very ugly, and for bug reports it
1295 dnl might be useful to have the original string.
1296 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1297 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1298 then
1299         AC_MSG_CHECKING(version of $LIBTOOL)
1300         CF_LIBTOOL_VERSION
1301         AC_MSG_RESULT($cf_cv_libtool_version)
1302         if test -z "$cf_cv_libtool_version" ; then
1303                 AC_MSG_ERROR(This is not GNU libtool)
1304         fi
1305 else
1306         AC_MSG_ERROR(GNU libtool has not been found)
1307 fi
1308 ])dnl
1309 dnl ---------------------------------------------------------------------------
1310 dnl CF_CHECK_WCHAR_H version: 2 updated: 2017/01/21 11:06:25
1311 dnl ----------------
1312 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1313 AC_DEFUN([CF_CHECK_WCHAR_H],[
1314 AC_CHECK_HEADERS( \
1315 wchar.h \
1316 wctype.h \
1317 )
1318 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1319 AC_TRY_COMPILE(
1320 [
1321 #include <stdlib.h>
1322 #ifdef HAVE_WCHAR_H
1323 #include <wchar.h>
1324 #endif
1325 #ifdef HAVE_WCTYPE_H
1326 #include <wctype.h>
1327 #endif
1328 ],[
1329         wint_t foo = 0;
1330         int bar = iswpunct(foo)],
1331         [cf_cv_wchar_h_okay=yes],
1332         [cf_cv_wchar_h_okay=no])])
1333
1334 if test $cf_cv_wchar_h_okay = no
1335 then
1336         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1337 fi
1338 ])dnl
1339 dnl ---------------------------------------------------------------------------
1340 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 1 updated: 2015/12/19 17:47:56
1341 dnl -------------------------
1342 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1343 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1344 dnl
1345 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1346 dnl all of those were combined into a page of useful graphics characters.
1347 dnl
1348 dnl So far, so good.
1349 dnl
1350 dnl However, while they are useful, there are other considerations.  CJK
1351 dnl is (because of poor device resolution) often rendered as double-width
1352 dnl characters.  So... for these generally-useful characters, what should
1353 dnl be the width (to make them consistent with adjacent characters)?
1354 dnl
1355 dnl The obvious choice would have been to make this locale-dependent, and use
1356 dnl wcwidth() to tell applications what the actual width is.  That was too
1357 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1358 dnl See for example
1359 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1360 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1361 dnl
1362 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1363 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1364 dnl instance, it lists half (44/96) of the Latin-1 characters as
1365 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1366 dnl
1367 dnl What this means for the implementor is that on some systems wcwidth() can
1368 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1369 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1370 dnl characters).  These do not necessarily match the behavior of the terminal
1371 dnl emulator.  xterm, for instance, does an optional startup check to find if
1372 dnl this problem (or similar) exists with the system's locale tables, rejecting
1373 dnl them if they are too unreliable.
1374 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1375 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1376 cat >conftest.in <<CF_EOF
1377 -       VT100 symbols
1378 0x250c  upper left corner
1379 0x2514  lower left corner
1380 0x2510  upper right corner
1381 0x2518  lower right corner
1382 0x251c  tee pointing left
1383 0x2524  tee pointing right
1384 0x2534  tee pointing up
1385 0x252c  tee pointing down
1386 0x2500  horizontal line
1387 0x2502  vertical line
1388 0x253c  large plus or crossover
1389 0x23ba  scan line 1
1390 0x23bd  scan line 9
1391 0x25c6  diamond
1392 0x2592  checker board (stipple)
1393 0x00b0  degree symbol
1394 0x00b1  plus/minus
1395 0x00b7  bullet
1396 -       Teletype 5410v1 symbols
1397 0x2190  arrow pointing left
1398 0x2192  arrow pointing right
1399 0x2193  arrow pointing down
1400 0x2191  arrow pointing up
1401 0x2592  board of squares
1402 0x2603  lantern symbol
1403 0x25ae  solid square block
1404 -       these defaults were invented for ncurses
1405 0x23bb  scan line 3
1406 0x23bc  scan line 7
1407 0x2264  less-than-or-equal-to
1408 0x2265  greater-than-or-equal-to
1409 0x03c0  greek pi
1410 0x2260  not-equal
1411 0x00a3  pound-sterling symbol
1412 -       thick-line-drawing
1413 0x250f  upper left corner
1414 0x2517  lower left corner
1415 0x2513  upper right corner
1416 0x251b  lower right corner
1417 0x2523  tee pointing left
1418 0x252b  tee pointing right
1419 0x253b  tee pointing up
1420 0x2533  tee pointing down
1421 0x2501  horizontal line
1422 0x2503  vertical line
1423 0x254b  large plus or crossover
1424 -       double-line-drawing
1425 0x2554  upper left corner
1426 0x255a  lower left corner
1427 0x2557  upper right corner
1428 0x255d  lower right corner
1429 0x2563  tee pointing left
1430 0x2560  tee pointing right
1431 0x2569  tee pointing up
1432 0x2566  tee pointing down
1433 0x2550  horizontal line
1434 0x2551  vertical line
1435 0x256c  large plus or crossover
1436 CF_EOF
1437 AC_TRY_RUN([
1438 #include <locale.h>
1439 #include <stdio.h>
1440 #include <wchar.h>
1441
1442 #define MY_LEN 80
1443
1444 int
1445 main(void)
1446 {
1447         FILE *fp;
1448         int value;
1449         char buffer[MY_LEN + 1];
1450         char notes[MY_LEN + 1];
1451         int totals = 0;
1452         int passed = 0;
1453
1454         if (setlocale(LC_ALL, "en_US.UTF8") ||
1455                 setlocale(LC_ALL, "en_US.UTF-8") ||
1456                 setlocale(LC_ALL, "en_US.utf8") ||
1457                 setlocale(LC_ALL, "en_US.utf-8")) {
1458                 if ((fp = fopen("conftest.in", "r")) != 0) {
1459                         while (fgets(buffer, MY_LEN, fp) != 0) {
1460                                 if (*buffer == '-') {
1461                                         fprintf(stderr, "\t%s", buffer);
1462                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1463                                         ++totals;
1464                                         if (wcwidth(value) == 1)
1465                                                 ++passed;
1466                                         fprintf(stderr, "%d\t%s", wcwidth(value), buffer);
1467                                 } else {
1468                                         fprintf(stderr, "?\t%s", buffer);
1469                                 }
1470                         }
1471                 }
1472         }
1473         fprintf(stderr, "%d/%d passed wcwidth/graphics check\n", passed, totals);
1474         return (totals == passed) ? 0 : 1;
1475 }
1476 ],
1477 [cf_cv_wcwidth_graphics=yes],
1478 [cf_cv_wcwidth_graphics=no],
1479 [cf_cv_wcwidth_graphics=unknown])
1480 ])
1481 ])dnl
1482 dnl ---------------------------------------------------------------------------
1483 dnl CF_CLANG_COMPILER version: 3 updated: 2020/08/28 04:10:22
1484 dnl -----------------
1485 dnl Check if the given compiler is really clang.  clang's C driver defines
1486 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1487 dnl not ignore some gcc options.
1488 dnl
1489 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1490 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1491 dnl the wrappers for gcc and g++ warnings.
1492 dnl
1493 dnl $1 = GCC (default) or GXX
1494 dnl $2 = CLANG_COMPILER (default)
1495 dnl $3 = CFLAGS (default) or CXXFLAGS
1496 AC_DEFUN([CF_CLANG_COMPILER],[
1497 ifelse([$2],,CLANG_COMPILER,[$2])=no
1498
1499 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1500         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1501         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1502         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
1503         AC_TRY_COMPILE([],[
1504 #ifdef __clang__
1505 #else
1506 make an error
1507 #endif
1508 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1509 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1510 ],[])
1511         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1512         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1513 fi
1514
1515 if test "x$CLANG_COMPILER" = "xyes" ; then
1516         CF_APPEND_TEXT(CFLAGS,-Wno-error=implicit-function-declaration)
1517 fi
1518 ])
1519 dnl ---------------------------------------------------------------------------
1520 dnl CF_CONST_X_STRING version: 4 updated: 2020/03/10 18:53:47
1521 dnl -----------------
1522 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
1523 dnl character-strings.
1524 dnl
1525 dnl It is ambiguous because the specification accommodated the pre-ANSI
1526 dnl compilers bundled by more than one vendor in lieu of providing a standard C
1527 dnl compiler other than by costly add-ons.  Because of this, the specification
1528 dnl did not take into account the use of const for telling the compiler that
1529 dnl string literals would be in readonly memory.
1530 dnl
1531 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
1532 dnl let the compiler decide how to represent Xt's strings which were #define'd.
1533 dnl That does not solve the problem of using the block of Xt's strings which
1534 dnl are compiled into the library (and is less efficient than one might want).
1535 dnl
1536 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
1537 dnl when compiling the library and compiling using the library, to tell the
1538 dnl compiler that String is const.
1539 AC_DEFUN([CF_CONST_X_STRING],
1540 [
1541 AC_REQUIRE([AC_PATH_XTRA])
1542
1543 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
1544
1545 AC_TRY_COMPILE(
1546 [
1547 #include <stdlib.h>
1548 #include <X11/Intrinsic.h>
1549 ],
1550 [String foo = malloc(1); (void)foo],[
1551
1552 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
1553         AC_TRY_COMPILE(
1554                 [
1555 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
1556 #undef  XTSTRINGDEFINES /* X11R5 and later */
1557 #include <stdlib.h>
1558 #include <X11/Intrinsic.h>
1559                 ],[String foo = malloc(1); *foo = 0],[
1560                         cf_cv_const_x_string=no
1561                 ],[
1562                         cf_cv_const_x_string=yes
1563                 ])
1564 ])
1565
1566 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
1567
1568 case $cf_cv_const_x_string in
1569 (no)
1570         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
1571         ;;
1572 (*)
1573         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
1574         ;;
1575 esac
1576
1577 ])
1578 ])dnl
1579 dnl ---------------------------------------------------------------------------
1580 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1581 dnl -----------------
1582 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1583 dnl is a late feature for the standard and is not in some recent compilers
1584 dnl (1999/9/11).
1585 AC_DEFUN([CF_CPP_PARAM_INIT],
1586 [
1587 if test -n "$CXX"; then
1588 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1589         AC_LANG_SAVE
1590         AC_LANG_CPLUSPLUS
1591         AC_TRY_RUN([
1592 class TEST {
1593 private:
1594         int value;
1595 public:
1596         TEST(int x = 1);
1597         ~TEST();
1598 };
1599
1600 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1601 {
1602         value = x;
1603 }
1604 int main(void) { }
1605 ],
1606         [cf_cv_cpp_param_init=yes],
1607         [cf_cv_cpp_param_init=no],
1608         [cf_cv_cpp_param_init=unknown])
1609         AC_LANG_RESTORE
1610 ])
1611 fi
1612 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1613 ])dnl
1614 dnl ---------------------------------------------------------------------------
1615 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1616 dnl ------------------
1617 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1618 dnl not be supported in g++ before 3.0
1619 AC_DEFUN([CF_CPP_STATIC_CAST],
1620 [
1621 if test -n "$CXX"; then
1622
1623 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1624         AC_LANG_SAVE
1625         AC_LANG_CPLUSPLUS
1626
1627         AC_TRY_COMPILE([
1628 class NCursesPanel
1629 {
1630 public:
1631   NCursesPanel(int nlines,
1632                int ncols,
1633                int begin_y = 0,
1634                int begin_x = 0)
1635   {
1636   }
1637   NCursesPanel();
1638   ~NCursesPanel();
1639 };
1640
1641 template<class T> class NCursesUserPanel : public NCursesPanel
1642 {
1643 public:
1644   NCursesUserPanel (int nlines,
1645                     int ncols,
1646                     int begin_y = 0,
1647                     int begin_x = 0,
1648                     const T* p_UserData = static_cast<T*>(0))
1649     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1650   {
1651   };
1652   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1653   {
1654   };
1655
1656   virtual ~NCursesUserPanel() {};
1657 };
1658 ],[
1659         const char* p_UserData = static_cast<char*>(0)],
1660         [cf_cv_cpp_static_cast=yes],
1661         [cf_cv_cpp_static_cast=no])
1662
1663         AC_LANG_RESTORE
1664 ])
1665
1666 fi
1667
1668 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1669 ])dnl
1670 dnl ---------------------------------------------------------------------------
1671 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1672 dnl ---------------
1673 dnl Setup special archiver flags for given compilers.
1674 AC_DEFUN([CF_CXX_AR_FLAGS],[
1675         CXX_AR='$(AR)'
1676         CXX_ARFLAGS='$(ARFLAGS)'
1677         case $cf_cv_system_name in
1678         (irix*)
1679             if test "$GXX" != yes ; then
1680                 CXX_AR='$(CXX)'
1681                 CXX_ARFLAGS='-ar -o'
1682             fi
1683             ;;
1684         (sco3.2v5*)
1685             CXXLDFLAGS="-u main"
1686             ;;
1687         (solaris2*)
1688             if test "$GXX" != yes ; then
1689                 CXX_AR='$(CXX)'
1690                 CXX_ARFLAGS='-xar -o'
1691             fi
1692             ;;
1693         esac
1694         AC_SUBST(CXXLDFLAGS)
1695         AC_SUBST(CXX_AR)
1696         AC_SUBST(CXX_ARFLAGS)
1697 ])dnl
1698 dnl ---------------------------------------------------------------------------
1699 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1700 dnl -------------------------
1701 dnl For c++, check if iostream uses "std::" namespace.
1702 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1703 AC_CHECK_HEADERS(iostream)
1704 if test x"$ac_cv_header_iostream" = xyes ; then
1705         AC_MSG_CHECKING(if iostream uses std-namespace)
1706         AC_TRY_COMPILE([
1707 #include <iostream>
1708 using std::endl;
1709 using std::cerr;],[
1710 cerr << "testing" << endl;
1711 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1712         AC_MSG_RESULT($cf_iostream_namespace)
1713         if test "$cf_iostream_namespace" = yes ; then
1714                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1715         fi
1716 fi
1717 ])dnl
1718 dnl ---------------------------------------------------------------------------
1719 dnl CF_C_INLINE version: 6 updated: 2019/09/07 13:38:36
1720 dnl -----------
1721 dnl Check if the C compiler supports "inline".
1722 dnl $1 is the name of a shell variable to set if inline is supported
1723 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1724 AC_DEFUN([CF_C_INLINE],[
1725 AC_REQUIRE([CF_GCC_VERSION])
1726 AC_C_INLINE
1727 $1=
1728 if test "$ac_cv_c_inline" != no ; then
1729         $1=inline
1730         if test "$INTEL_COMPILER" = yes
1731         then
1732                 :
1733         elif test "$CLANG_COMPILER" = yes
1734         then
1735                 :
1736         elif test "$GCC" = yes
1737         then
1738                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1739                 cf_save_CFLAGS=$CFLAGS
1740                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1741                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1742                 [${cf_cv_main_return:-return} foo()],
1743                 [cf_cv_gcc_inline=yes],
1744                 [cf_cv_gcc_inline=no])
1745                 CFLAGS=$cf_save_CFLAGS
1746                 ])
1747                 if test "$cf_cv_gcc_inline" = yes ; then
1748                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1749                 fi
1750         fi
1751 fi
1752 AC_SUBST($1)
1753 ])dnl
1754 dnl ---------------------------------------------------------------------------
1755 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1756 dnl ----------
1757 dnl "dirname" is not portable, so we fake it with a shell script.
1758 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1759 dnl ---------------------------------------------------------------------------
1760 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1761 dnl ---------------
1762 AC_DEFUN([CF_DIRS_TO_MAKE],
1763 [
1764 DIRS_TO_MAKE="lib"
1765 for cf_item in $cf_list_models
1766 do
1767         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1768         for cf_item2 in $DIRS_TO_MAKE
1769         do
1770                 test $cf_item2 = $cf_subdir && break
1771         done
1772         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1773 done
1774 for cf_dir in $DIRS_TO_MAKE
1775 do
1776         test ! -d $cf_dir && mkdir $cf_dir
1777 done
1778 AC_SUBST(DIRS_TO_MAKE)
1779 ])dnl
1780 dnl ---------------------------------------------------------------------------
1781 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1782 dnl ---------------
1783 dnl You can always use "make -n" to see the actual options, but it's hard to
1784 dnl pick out/analyze warning messages when the compile-line is long.
1785 dnl
1786 dnl Sets:
1787 dnl     ECHO_LT - symbol to control if libtool is verbose
1788 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1789 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1790 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1791 dnl     ECHO_CC - symbol to put before any "cc" line
1792 dnl
1793 AC_DEFUN([CF_DISABLE_ECHO],[
1794 AC_MSG_CHECKING(if you want to see long compiling messages)
1795 CF_ARG_DISABLE(echo,
1796         [  --disable-echo          do not display "compiling" commands],
1797         [
1798         ECHO_LT='--silent'
1799         ECHO_LD='@echo linking [$]@;'
1800         RULE_CC='@echo compiling [$]<'
1801         SHOW_CC='@echo compiling [$]@'
1802         ECHO_CC='@'
1803 ],[
1804         ECHO_LT=''
1805         ECHO_LD=''
1806         RULE_CC=''
1807         SHOW_CC=''
1808         ECHO_CC=''
1809 ])
1810 AC_MSG_RESULT($enableval)
1811 AC_SUBST(ECHO_LT)
1812 AC_SUBST(ECHO_LD)
1813 AC_SUBST(RULE_CC)
1814 AC_SUBST(SHOW_CC)
1815 AC_SUBST(ECHO_CC)
1816 ])dnl
1817 dnl ---------------------------------------------------------------------------
1818 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1819 dnl ------------------------
1820 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1821 AC_MSG_CHECKING(if we want to use GNAT projects)
1822 CF_ARG_DISABLE(gnat-projects,
1823         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1824         [enable_gnat_projects=no],
1825         [enable_gnat_projects=yes])
1826 AC_MSG_RESULT($enable_gnat_projects)
1827 ])dnl
1828 dnl ---------------------------------------------------------------------------
1829 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1830 dnl ----------------
1831 dnl Combine no-leak checks with the libraries or tools that are used for the
1832 dnl checks.
1833 AC_DEFUN([CF_DISABLE_LEAKS],[
1834
1835 AC_REQUIRE([CF_WITH_DMALLOC])
1836 AC_REQUIRE([CF_WITH_DBMALLOC])
1837 AC_REQUIRE([CF_WITH_VALGRIND])
1838
1839 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1840 AC_ARG_ENABLE(leaks,
1841         [  --disable-leaks         test: free permanent memory, analyze leaks],
1842         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1843         : ${with_no_leaks:=no})
1844 AC_MSG_RESULT($with_no_leaks)
1845
1846 if test "$with_no_leaks" = yes ; then
1847         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1848         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1849 fi
1850 ])dnl
1851 dnl ---------------------------------------------------------------------------
1852 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1853 dnl --------------------------
1854 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1855 dnl the older "-version-info" feature.  The newer feature allows us to use
1856 dnl version numbering on shared libraries which make them compatible with
1857 dnl various systems.
1858 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1859 [
1860 AC_MSG_CHECKING(if libtool -version-number should be used)
1861 CF_ARG_DISABLE(libtool-version,
1862         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1863         [cf_libtool_version=no],
1864         [cf_libtool_version=yes])
1865 AC_MSG_RESULT($cf_libtool_version)
1866
1867 if test "$cf_libtool_version" = yes ; then
1868         LIBTOOL_VERSION="-version-number"
1869 else
1870         LIBTOOL_VERSION="-version-info"
1871         case "x$VERSION" in
1872         (x)
1873                 AC_MSG_WARN(VERSION was not set)
1874                 ;;
1875         (x*.*.*)
1876                 ABI_VERSION="$VERSION"
1877                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1878                 ;;
1879         (x*:*:*)
1880                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1881                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1882                 ;;
1883         (*)
1884                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1885                 ;;
1886         esac
1887 fi
1888
1889 AC_SUBST(ABI_VERSION)
1890 AC_SUBST(LIBTOOL_VERSION)
1891 ])dnl
1892 dnl ---------------------------------------------------------------------------
1893 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1894 dnl ---------------------
1895 dnl The rpath-hack makes it simpler to build programs, particularly with the
1896 dnl *BSD ports which may have essential libraries in unusual places.  But it
1897 dnl can interfere with building an executable for the base system.  Use this
1898 dnl option in that case.
1899 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1900 [
1901 AC_MSG_CHECKING(if rpath-hack should be disabled)
1902 CF_ARG_DISABLE(rpath-hack,
1903         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1904         [cf_disable_rpath_hack=yes],
1905         [cf_disable_rpath_hack=no])
1906 AC_MSG_RESULT($cf_disable_rpath_hack)
1907 if test "$cf_disable_rpath_hack" = no ; then
1908         CF_RPATH_HACK
1909 fi
1910 ])
1911 dnl ---------------------------------------------------------------------------
1912 dnl CF_ENABLE_BROKEN_LINKER version: 1 updated: 2020/02/08 15:59:30
1913 dnl -----------------------
1914 dnl Some linkers cannot reference a data-only object.  Cygwin used to be one.
1915 dnl This usually follows CF_LINK_DATAONLY, but is not required in case we need
1916 dnl an unconditional feature.
1917 AC_DEFUN([CF_ENABLE_BROKEN_LINKER],[
1918
1919 AC_MSG_CHECKING(if you want broken-linker support code)
1920 AC_ARG_ENABLE(broken_linker,
1921         [  --enable-broken_linker  compile with broken-linker support code],
1922         [with_broken_linker=$enableval],
1923         [with_broken_linker=no])
1924 AC_MSG_RESULT($with_broken_linker)
1925
1926 : ${BROKEN_LINKER:=0}
1927 if test "x$with_broken_linker" = xyes ; then
1928         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
1929         BROKEN_LINKER=1
1930 fi
1931 AC_SUBST(BROKEN_LINKER)
1932 ])dnl
1933 dnl ---------------------------------------------------------------------------
1934 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
1935 dnl ------------------
1936 dnl This is the "--enable-pc-files" option, which is available if there is a
1937 dnl pkg-config configuration on the local machine.
1938 AC_DEFUN([CF_ENABLE_PC_FILES],[
1939 AC_REQUIRE([CF_PKG_CONFIG])
1940 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1941
1942 if test "x$PKG_CONFIG" != xnone
1943 then
1944         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1945 else
1946         AC_MSG_CHECKING(if we should install .pc files)
1947 fi
1948
1949 AC_ARG_ENABLE(pc-files,
1950         [  --enable-pc-files       generate and install .pc files for pkg-config],
1951         [enable_pc_files=$enableval],
1952         [enable_pc_files=no])
1953 AC_MSG_RESULT($enable_pc_files)
1954
1955 if test "x$enable_pc_files" != xno
1956 then
1957         MAKE_PC_FILES=
1958         case "x$PKG_CONFIG_LIBDIR" in
1959         (xno|xyes)
1960                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1961                 ;;
1962         (*)
1963                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1964                 ;;
1965         esac
1966 else
1967         MAKE_PC_FILES="#"
1968 fi
1969 AC_SUBST(MAKE_PC_FILES)
1970 ])dnl
1971 dnl ---------------------------------------------------------------------------
1972 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1973 dnl ---------------
1974 dnl Check if the rpath option should be used, setting cache variable
1975 dnl cf_cv_enable_rpath if so.
1976 AC_DEFUN([CF_ENABLE_RPATH],
1977 [
1978 AC_MSG_CHECKING(if rpath option should be used)
1979 AC_ARG_ENABLE(rpath,
1980 [  --enable-rpath          use rpath option when generating shared libraries],
1981 [cf_cv_enable_rpath=$enableval],
1982 [cf_cv_enable_rpath=no])
1983 AC_MSG_RESULT($cf_cv_enable_rpath)
1984 ])dnl
1985 dnl ---------------------------------------------------------------------------
1986 dnl CF_ENABLE_STRING_HACKS version: 5 updated: 2016/10/08 17:34:11
1987 dnl ----------------------
1988 dnl On a few platforms, the compiler and/or loader nags with untruthful
1989 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1990 dnl and implying that most uses of the recommended alternatives are correct.
1991 dnl
1992 dnl Factually speaking, no one has actually counted the number of uses of these
1993 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1994 dnl instances are meaningless compared to the hundreds of millions of lines of
1995 dnl existing C code.
1996 dnl
1997 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1998 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1999 dnl standard - but evolved through phases, and older implementations are likely
2000 dnl to yield surprising results, as documented in manpages on various systems.
2001 AC_DEFUN([CF_ENABLE_STRING_HACKS],
2002 [
2003 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
2004 AC_ARG_ENABLE(string-hacks,
2005         [  --enable-string-hacks   work around bogus compiler/loader warnings],
2006         [with_string_hacks=$enableval],
2007         [with_string_hacks=no])
2008 AC_MSG_RESULT($with_string_hacks)
2009
2010 if test "x$with_string_hacks" = "xyes"; then
2011         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
2012         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
2013         AC_CHECK_FUNC(strlcat,[
2014                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2015                 ],[
2016                 AC_CHECK_LIB(bsd,strlcat,[
2017                         CF_ADD_LIB(bsd)
2018                         AC_CHECK_HEADERS(bsd/string.h)
2019                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2020                         ])
2021                 ])
2022         AC_CHECK_FUNCS( strlcpy snprintf )
2023 fi
2024 ])dnl
2025 dnl ---------------------------------------------------------------------------
2026 dnl CF_ENABLE_WARNINGS version: 7 updated: 2020/08/29 09:05:21
2027 dnl ------------------
2028 dnl Configure-option to enable gcc warnings
2029 dnl
2030 dnl $1 = extra options to add, if supported
2031 dnl $2 = option for checking attributes.  By default, this is done when
2032 dnl      warnings are enabled.  For other values:
2033 dnl      yes: always do this, e.g., to use in generated library-headers
2034 dnl      no: never do this
2035 AC_DEFUN([CF_ENABLE_WARNINGS],[
2036 if ( test "$GCC" = yes || test "$GXX" = yes )
2037 then
2038 CF_FIX_WARNINGS(CFLAGS)
2039 CF_FIX_WARNINGS(CPPFLAGS)
2040 CF_FIX_WARNINGS(LDFLAGS)
2041 AC_MSG_CHECKING(if you want to turn on gcc warnings)
2042 CF_ARG_ENABLE(warnings,
2043         [  --enable-warnings       test: turn on gcc compiler warnings],
2044         [with_warnings=yes],
2045         [with_warnings=no])
2046 AC_MSG_RESULT($with_warnings)
2047 if test "$with_warnings" = "yes"
2048 then
2049         ifelse($2,,[CF_GCC_ATTRIBUTES])
2050         CF_GCC_WARNINGS($1)
2051 fi
2052 ifelse($2,yes,[CF_GCC_ATTRIBUTES])
2053 fi
2054 ])dnl
2055 dnl ---------------------------------------------------------------------------
2056 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
2057 dnl --------
2058 dnl Check if 'errno' is declared in <errno.h>
2059 AC_DEFUN([CF_ERRNO],
2060 [
2061 CF_CHECK_ERRNO(errno)
2062 ])dnl
2063 dnl ---------------------------------------------------------------------------
2064 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
2065 dnl ---------------
2066 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
2067 dnl math.h and builtin.h, only for ncurses
2068 AC_DEFUN([CF_ETIP_DEFINES],
2069 [
2070 AC_MSG_CHECKING(for special defines needed for etip.h)
2071 cf_save_CXXFLAGS="$CXXFLAGS"
2072 cf_result="none"
2073
2074 # etip.h includes ncurses.h which includes ncurses_dll.h
2075 # But ncurses_dll.h is generated - fix here.
2076 test -d include || mkdir include
2077 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
2078
2079 for cf_math in "" MATH_H
2080 do
2081 for cf_excp in "" MATH_EXCEPTION
2082 do
2083         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
2084         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
2085         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
2086 AC_TRY_COMPILE([
2087 #include <etip.h.in>
2088 ],[],[
2089         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
2090         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
2091         cf_result="$cf_math $cf_excp"
2092         break 2
2093 ],[])
2094 done
2095 done
2096 AC_MSG_RESULT($cf_result)
2097 CXXFLAGS="$cf_save_CXXFLAGS"
2098 ])
2099 dnl ---------------------------------------------------------------------------
2100 dnl CF_FIND_LINKAGE version: 21 updated: 2018/06/20 20:23:13
2101 dnl ---------------
2102 dnl Find a library (specifically the linkage used in the code fragment),
2103 dnl searching for it if it is not already in the library path.
2104 dnl See also CF_ADD_SEARCHPATH.
2105 dnl
2106 dnl Parameters (4-on are optional):
2107 dnl     $1 = headers for library entrypoint
2108 dnl     $2 = code fragment for library entrypoint
2109 dnl     $3 = the library name without the "-l" option or ".so" suffix.
2110 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
2111 dnl     $5 = action to perform if not successful
2112 dnl     $6 = module name, if not the same as the library name
2113 dnl     $7 = extra libraries
2114 dnl
2115 dnl Sets these variables:
2116 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
2117 dnl     $cf_cv_header_path_$3 - include-directory if needed
2118 dnl     $cf_cv_library_path_$3 - library-directory if needed
2119 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
2120 AC_DEFUN([CF_FIND_LINKAGE],[
2121
2122 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
2123 # will be set on completion of the AC_TRY_LINK below.
2124 cf_cv_header_path_$3=
2125 cf_cv_library_path_$3=
2126
2127 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
2128
2129 cf_save_LIBS="$LIBS"
2130
2131 AC_TRY_LINK([$1],[$2],[
2132         cf_cv_find_linkage_$3=yes
2133         cf_cv_header_path_$3=/usr/include
2134         cf_cv_library_path_$3=/usr/lib
2135 ],[
2136
2137 LIBS="-l$3 $7 $cf_save_LIBS"
2138
2139 AC_TRY_LINK([$1],[$2],[
2140         cf_cv_find_linkage_$3=yes
2141         cf_cv_header_path_$3=/usr/include
2142         cf_cv_library_path_$3=/usr/lib
2143         cf_cv_library_file_$3="-l$3"
2144 ],[
2145         cf_cv_find_linkage_$3=no
2146         LIBS="$cf_save_LIBS"
2147
2148         CF_VERBOSE(find linkage for $3 library)
2149         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
2150
2151         cf_save_CPPFLAGS="$CPPFLAGS"
2152         cf_test_CPPFLAGS="$CPPFLAGS"
2153
2154         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
2155         for cf_cv_header_path_$3 in $cf_search
2156         do
2157                 if test -d $cf_cv_header_path_$3 ; then
2158                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
2159                         CPPFLAGS="$cf_save_CPPFLAGS"
2160                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
2161                         AC_TRY_COMPILE([$1],[$2],[
2162                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
2163                                 cf_cv_find_linkage_$3=maybe
2164                                 cf_test_CPPFLAGS="$CPPFLAGS"
2165                                 break],[
2166                                 CPPFLAGS="$cf_save_CPPFLAGS"
2167                                 ])
2168                 fi
2169         done
2170
2171         if test "$cf_cv_find_linkage_$3" = maybe ; then
2172
2173                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
2174
2175                 cf_save_LIBS="$LIBS"
2176                 cf_save_LDFLAGS="$LDFLAGS"
2177
2178                 ifelse([$6],,,[
2179                 CPPFLAGS="$cf_test_CPPFLAGS"
2180                 LIBS="-l$3 $7 $cf_save_LIBS"
2181                 AC_TRY_LINK([$1],[$2],[
2182                         CF_VERBOSE(... found $3 library in system)
2183                         cf_cv_find_linkage_$3=yes])
2184                         CPPFLAGS="$cf_save_CPPFLAGS"
2185                         LIBS="$cf_save_LIBS"
2186                         ])
2187
2188                 if test "$cf_cv_find_linkage_$3" != yes ; then
2189                         CF_LIBRARY_PATH(cf_search,$3)
2190                         for cf_cv_library_path_$3 in $cf_search
2191                         do
2192                                 if test -d $cf_cv_library_path_$3 ; then
2193                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
2194                                         CPPFLAGS="$cf_test_CPPFLAGS"
2195                                         LIBS="-l$3 $7 $cf_save_LIBS"
2196                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
2197                                         AC_TRY_LINK([$1],[$2],[
2198                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
2199                                         cf_cv_find_linkage_$3=yes
2200                                         cf_cv_library_file_$3="-l$3"
2201                                         break],[
2202                                         CPPFLAGS="$cf_save_CPPFLAGS"
2203                                         LIBS="$cf_save_LIBS"
2204                                         LDFLAGS="$cf_save_LDFLAGS"
2205                                         ])
2206                                 fi
2207                         done
2208                         CPPFLAGS="$cf_save_CPPFLAGS"
2209                         LDFLAGS="$cf_save_LDFLAGS"
2210                 fi
2211
2212         else
2213                 cf_cv_find_linkage_$3=no
2214         fi
2215         ],$7)
2216 ])
2217
2218 LIBS="$cf_save_LIBS"
2219
2220 if test "$cf_cv_find_linkage_$3" = yes ; then
2221 ifelse([$4],,[
2222         CF_ADD_INCDIR($cf_cv_header_path_$3)
2223         CF_ADD_LIBDIR($cf_cv_library_path_$3)
2224         CF_ADD_LIB($3)
2225 ],[$4])
2226 else
2227 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
2228 fi
2229 ])dnl
2230 dnl ---------------------------------------------------------------------------
2231 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
2232 dnl ------------------
2233 dnl Find an include-directory with the given leaf-name.  This is useful for
2234 dnl example with FreeBSD ports, which use this convention to distinguish
2235 dnl different versions of the same port.
2236 AC_DEFUN([CF_FIND_SUB_INCDIR],[
2237         CF_SUBDIR_PATH(cf_search,$1,include)
2238         for cf_item in $cf_search
2239         do
2240                 case $cf_item in
2241                 (*/$1)
2242                         CF_ADD_INCDIR($cf_item)
2243                         ;;
2244                 esac
2245         done
2246 ])dnl
2247 dnl ---------------------------------------------------------------------------
2248 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
2249 dnl ------------------
2250 dnl Find a library-directory with the given leaf-name.  This is useful for
2251 dnl example with FreeBSD ports, which use this convention to distinguish
2252 dnl different versions of the same port.
2253 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
2254         CF_SUBDIR_PATH(cf_search,$1,lib)
2255         for cf_item in $cf_search
2256         do
2257                 case $cf_item in
2258                 (*/$1)
2259                         CF_ADD_LIBDIR($cf_item)
2260                         ;;
2261                 esac
2262         done
2263 ])dnl
2264 dnl ---------------------------------------------------------------------------
2265 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
2266 dnl -----------------
2267 dnl make ADAFLAGS consistent with CFLAGS
2268 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
2269         AC_MSG_CHECKING(optimization options for ADAFLAGS)
2270         case "$CFLAGS" in
2271         (*-g*)
2272                 CF_ADD_ADAFLAGS(-g)
2273                 ;;
2274         esac
2275         case "$CFLAGS" in
2276         (*-O*)
2277                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
2278                 CF_ADD_ADAFLAGS($cf_O_flag)
2279                 ;;
2280         esac
2281         AC_MSG_RESULT($ADAFLAGS)
2282 ])dnl
2283 dnl ---------------------------------------------------------------------------
2284 dnl CF_FIX_WARNINGS version: 2 updated: 2020/08/28 15:08:28
2285 dnl ---------------
2286 dnl Warning flags do not belong in CFLAGS, CPPFLAGS, etc.  Any of gcc's
2287 dnl "-Werror" flags can interfere with configure-checks.  Those go into
2288 dnl EXTRA_CFLAGS.
2289 dnl
2290 dnl $1 = variable name to repair
2291 define([CF_FIX_WARNINGS],[
2292 if ( test "$GCC" = yes || test "$GXX" = yes )
2293 then
2294         case [$]$1 in
2295         (*-Werror=*)
2296                 CF_VERBOSE(repairing $1: [$]$1)
2297                 cf_temp_flags=
2298                 for cf_temp_scan in [$]$1
2299                 do
2300                         case "x$cf_temp_scan" in
2301                         (x-Werror=*)
2302                                 CF_APPEND_TEXT(EXTRA_CFLAGS,"$cf_temp_scan")
2303                                 ;;
2304                         (*)
2305                                 CF_APPEND_TEXT(cf_temp_flags,"$cf_temp_scan")
2306                                 ;;
2307                         esac
2308                 done
2309                 $1="$cf_temp_flags"
2310                 CF_VERBOSE(... fixed [$]$1)
2311                 CF_VERBOSE(... extra $EXTRA_CFLAGS)
2312                 ;;
2313         esac
2314 fi
2315 AC_SUBST(EXTRA_CFLAGS)
2316 ])dnl
2317 dnl ---------------------------------------------------------------------------
2318 dnl CF_FOPEN_BIN_R version: 2 updated: 2019/12/31 08:53:54
2319 dnl --------------
2320 dnl Check if fopen works when the "b" (binary) flag is added to the mode
2321 dnl parameter.  POSIX ignores the "b", which c89 specified.  Some very old
2322 dnl systems do not accept it.
2323 AC_DEFUN([CF_FOPEN_BIN_R],[
2324 AC_CACHE_CHECK(if fopen accepts explicit binary mode,cf_cv_fopen_bin_r,[
2325         AC_TRY_RUN([
2326 #include <stdio.h>
2327 int main(void) {
2328         FILE *fp = fopen("conftest.tmp", "wb");
2329         int rc = 0;
2330         if (fp != 0) {
2331                 int p, q;
2332                 for (p = 0; p < 256; ++p) {
2333                         fputc(p, fp);
2334                 }
2335                 fclose(fp);
2336                 fp = fopen("conftest.tmp", "rb");
2337                 if (fp != 0) {
2338                         for (p = 0; p < 256; ++p) {
2339                                 q = fgetc(fp);
2340                                 if (q != p) {
2341                                         rc = 1;
2342                                         break;
2343                                 }
2344                         }
2345                 } else {
2346                         rc = 1;
2347                 }
2348         } else {
2349                 rc = 1;
2350         }
2351         ${cf_cv_main_return:-return} (rc);
2352 }
2353 ],
2354                 [cf_cv_fopen_bin_r=yes],
2355                 [cf_cv_fopen_bin_r=no],
2356                 [cf_cv_fopen_bin_r=unknown])
2357 ])
2358 test "x$cf_cv_fopen_bin_r" != xno && AC_DEFINE(USE_FOPEN_BIN_R,1,[Define to 1 if fopen accepts explicit binary mode])
2359 ])dnl
2360 dnl ---------------------------------------------------------------------------
2361 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
2362 dnl --------------
2363 dnl Forget that we saw the given tool.
2364 AC_DEFUN([CF_FORGET_TOOL],[
2365 unset ac_cv_prog_ac_ct_$1
2366 unset ac_ct_$1
2367 unset $1
2368 ])dnl
2369 dnl ---------------------------------------------------------------------------
2370 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
2371 dnl -------------
2372 dnl Test for dlsym() and related functions, as well as libdl.
2373 dnl
2374 dnl Sets
2375 dnl     $cf_have_dlsym
2376 dnl     $cf_have_libdl
2377 AC_DEFUN([CF_FUNC_DLSYM],[
2378 cf_have_dlsym=no
2379 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
2380
2381 cf_have_libdl=no
2382 AC_CHECK_LIB(dl,dlsym,[
2383         cf_have_dlsym=yes
2384         cf_have_libdl=yes])])
2385
2386 if test "$cf_have_dlsym" = yes ; then
2387         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
2388
2389         AC_MSG_CHECKING(whether able to link to dl*() functions)
2390         AC_TRY_LINK([#include <dlfcn.h>],[
2391                 void *obj;
2392                 if ((obj = dlopen("filename", 0)) != 0) {
2393                         if (dlsym(obj, "symbolname") == 0) {
2394                         dlclose(obj);
2395                         }
2396                 }],[
2397                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
2398                 AC_MSG_ERROR(Cannot link test program for libdl)])
2399         AC_MSG_RESULT(ok)
2400 else
2401         AC_MSG_ERROR(Cannot find dlsym function)
2402 fi
2403 ])
2404 dnl ---------------------------------------------------------------------------
2405 dnl CF_FUNC_MEMMOVE version: 9 updated: 2017/01/21 11:06:25
2406 dnl ---------------
2407 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
2408 dnl is found, add our own version of memmove to the list of objects.
2409 AC_DEFUN([CF_FUNC_MEMMOVE],
2410 [
2411 AC_CHECK_FUNC(memmove,,[
2412 AC_CHECK_FUNC(bcopy,[
2413         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
2414                 AC_TRY_RUN([
2415 int main(void) {
2416         static char data[] = "abcdefghijklmnopqrstuwwxyz";
2417         char temp[40];
2418         bcopy(data, temp, sizeof(data));
2419         bcopy(temp+10, temp, 15);
2420         bcopy(temp+5, temp+15, 10);
2421         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
2422 }
2423                 ],
2424                 [cf_cv_good_bcopy=yes],
2425                 [cf_cv_good_bcopy=no],
2426                 [cf_cv_good_bcopy=unknown])
2427                 ])
2428         ],[cf_cv_good_bcopy=no])
2429         if test "$cf_cv_good_bcopy" = yes ; then
2430                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
2431         else
2432                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
2433         fi
2434 ])])dnl
2435 dnl ---------------------------------------------------------------------------
2436 dnl CF_FUNC_NANOSLEEP version: 5 updated: 2017/01/21 11:06:25
2437 dnl -----------------
2438 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
2439 dnl AIX 4.x, provide a non-working version.
2440 AC_DEFUN([CF_FUNC_NANOSLEEP],[
2441 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
2442 AC_TRY_RUN([
2443 #include <stdio.h>
2444 #include <errno.h>
2445 #include <time.h>
2446
2447 #ifdef HAVE_SYS_TIME_H
2448 #include <sys/time.h>
2449 #endif
2450
2451 int main(void) {
2452         struct timespec ts1, ts2;
2453         int code;
2454         ts1.tv_sec  = 0;
2455         ts1.tv_nsec = 750000000;
2456         ts2.tv_sec  = 0;
2457         ts2.tv_nsec = 0;
2458         errno = 0;
2459         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
2460         ${cf_cv_main_return:-return}(code != 0);
2461 }
2462 ],
2463         [cf_cv_func_nanosleep=yes],
2464         [cf_cv_func_nanosleep=no],
2465         [cf_cv_func_nanosleep=unknown])])
2466
2467 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
2468 ])
2469 dnl ---------------------------------------------------------------------------
2470 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
2471 dnl ---------------
2472 dnl Check for openpty() function, along with <pty.h> header.  It may need the
2473 dnl "util" library as well.
2474 AC_DEFUN([CF_FUNC_OPENPTY],
2475 [
2476 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
2477 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
2478         cf_save_LIBS="$LIBS"
2479         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
2480         for cf_header in pty.h libutil.h util.h
2481         do
2482         AC_TRY_LINK([
2483 #include <$cf_header>
2484 ],[
2485         int x = openpty((int *)0, (int *)0, (char *)0,
2486                                    (struct termios *)0, (struct winsize *)0);
2487 ],[
2488                 cf_cv_func_openpty=$cf_header
2489                 break
2490 ],[
2491                 cf_cv_func_openpty=no
2492 ])
2493         done
2494         LIBS="$cf_save_LIBS"
2495 ])
2496 ])dnl
2497 dnl ---------------------------------------------------------------------------
2498 dnl CF_FUNC_POLL version: 9 updated: 2015/10/10 13:27:32
2499 dnl ------------
2500 dnl See if the poll function really works.  Some platforms have poll(), but
2501 dnl it does not work for terminals or files.
2502 AC_DEFUN([CF_FUNC_POLL],[
2503 tty 2>&1 >/dev/null || { AC_CHECK_FUNCS(posix_openpt) }
2504 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2505 AC_TRY_RUN([
2506 #include <stdlib.h>
2507 #include <stdio.h>
2508 #include <unistd.h>
2509 #include <fcntl.h>
2510 #ifdef HAVE_POLL_H
2511 #include <poll.h>
2512 #else
2513 #include <sys/poll.h>
2514 #endif
2515 int main(void) {
2516         struct pollfd myfds;
2517         int ret;
2518
2519         /* check for Darwin bug with respect to "devices" */
2520         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2521         if (myfds.fd < 0)
2522                 myfds.fd = 0;
2523         myfds.events = POLLIN;
2524         myfds.revents = 0;
2525
2526         ret = poll(&myfds, 1, 100);
2527
2528         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2529                 ret = -1;
2530         } else {
2531                 int fd = 0;
2532                 if (!isatty(fd)) {
2533                         fd = open("/dev/tty", 2);       /* O_RDWR */
2534                 }
2535 #ifdef HAVE_POSIX_OPENPT
2536                 if (fd < 0) {
2537                         fd = posix_openpt(O_RDWR);
2538                 }
2539 #endif
2540
2541                 if (fd >= 0) {
2542                         /* also check with standard input */
2543                         myfds.fd = fd;
2544                         myfds.events = POLLIN;
2545                         myfds.revents = 0;
2546                         ret = poll(&myfds, 1, 100);
2547                 } else {
2548                         ret = -1;
2549                 }
2550         }
2551         ${cf_cv_main_return:-return}(ret < 0);
2552 }],
2553         [cf_cv_working_poll=yes],
2554         [cf_cv_working_poll=no],
2555         [cf_cv_working_poll=unknown])])
2556 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2557 ])dnl
2558 dnl ---------------------------------------------------------------------------
2559 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2560 dnl ---------------
2561 dnl Some old/broken variations define tcgetattr() only as a macro in
2562 dnl termio(s).h
2563 AC_DEFUN([CF_FUNC_TERMIOS],[
2564 AC_REQUIRE([CF_STRUCT_TERMIOS])
2565 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2566 AC_TRY_LINK([
2567 #include <sys/types.h>
2568 #ifdef HAVE_UNISTD_H
2569 #include <unistd.h>
2570 #endif
2571 #ifdef HAVE_TERMIOS_H
2572 #include <termios.h>
2573 #define TTY struct termios
2574 #else
2575 #ifdef HAVE_TERMIO_H
2576 #include <termio.h>
2577 #define TTY struct termio
2578 #endif
2579 #endif
2580 ],[
2581 TTY foo;
2582 tcgetattr(1, &foo);],
2583 [cf_cv_have_tcgetattr=yes],
2584 [cf_cv_have_tcgetattr=no])])
2585 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2586 ])dnl
2587 dnl ---------------------------------------------------------------------------
2588 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
2589 dnl ---------------
2590 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2591 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2592 dnl other functions.
2593 AC_DEFUN([CF_FUNC_VSSCANF],
2594 [
2595 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2596 AC_TRY_LINK([
2597 #include <stdarg.h>
2598 #include <stdio.h>],[
2599         va_list ap;
2600         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2601 AC_TRY_LINK([
2602 #include <stdarg.h>
2603 #include <stdio.h>],[
2604         FILE strbuf;
2605         char *str = "from";
2606
2607         strbuf._flag = _IOREAD;
2608         strbuf._ptr = strbuf._base = (unsigned char *) str;
2609         strbuf._cnt = strlen(str);
2610         strbuf._file = _NFILE;
2611         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2612 AC_TRY_LINK([
2613 #include <stdarg.h>
2614 #include <stdio.h>],[
2615         FILE strbuf;
2616         char *str = "from";
2617
2618         strbuf._flag = _IOREAD;
2619         strbuf._ptr = strbuf._base = (unsigned char *) str;
2620         strbuf._cnt = strlen(str);
2621         strbuf._file = _NFILE;
2622         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2623 cf_cv_func_vsscanf=no])])])])
2624
2625 case $cf_cv_func_vsscanf in
2626 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2627 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2628 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2629 esac
2630
2631 ])dnl
2632 dnl ---------------------------------------------------------------------------
2633 dnl CF_GCC_ATTRIBUTES version: 19 updated: 2020/08/29 09:05:21
2634 dnl -----------------
2635 dnl Test for availability of useful gcc __attribute__ directives to quiet
2636 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2637 dnl to documentation, unrecognized directives cause older compilers to barf.
2638 AC_DEFUN([CF_GCC_ATTRIBUTES],
2639 [
2640 if ( test "$GCC" = yes || test "$GXX" = yes )
2641 then
2642 cat > conftest.i <<EOF
2643 #ifndef GCC_PRINTF
2644 #define GCC_PRINTF 0
2645 #endif
2646 #ifndef GCC_SCANF
2647 #define GCC_SCANF 0
2648 #endif
2649 #ifndef GCC_NORETURN
2650 #define GCC_NORETURN /* nothing */
2651 #endif
2652 #ifndef GCC_UNUSED
2653 #define GCC_UNUSED /* nothing */
2654 #endif
2655 EOF
2656 if test "$GCC" = yes
2657 then
2658         AC_CHECKING([for $CC __attribute__ directives])
2659 cat > conftest.$ac_ext <<EOF
2660 #line __oline__ "${as_me:-configure}"
2661 #include "confdefs.h"
2662 #include "conftest.h"
2663 #include "conftest.i"
2664 #if     GCC_PRINTF
2665 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2666 #else
2667 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2668 #endif
2669 #if     GCC_SCANF
2670 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2671 #else
2672 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2673 #endif
2674 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2675 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
2676 extern void foo(void) GCC_NORETURN;
2677 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
2678 EOF
2679         cf_printf_attribute=no
2680         cf_scanf_attribute=no
2681         for cf_attribute in scanf printf unused noreturn
2682         do
2683                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2684                 cf_directive="__attribute__(($cf_attribute))"
2685                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2686
2687                 case $cf_attribute in
2688                 (printf)
2689                         cf_printf_attribute=yes
2690                         cat >conftest.h <<EOF
2691 #define GCC_$cf_ATTRIBUTE 1
2692 EOF
2693                         ;;
2694                 (scanf)
2695                         cf_scanf_attribute=yes
2696                         cat >conftest.h <<EOF
2697 #define GCC_$cf_ATTRIBUTE 1
2698 EOF
2699                         ;;
2700                 (*)
2701                         cat >conftest.h <<EOF
2702 #define GCC_$cf_ATTRIBUTE $cf_directive
2703 EOF
2704                         ;;
2705                 esac
2706
2707                 if AC_TRY_EVAL(ac_compile); then
2708                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2709                         cat conftest.h >>confdefs.h
2710                         case $cf_attribute in
2711                         (noreturn)
2712                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2713                                 ;;
2714                         (printf)
2715                                 cf_value='/* nothing */'
2716                                 if test "$cf_printf_attribute" != no ; then
2717                                         cf_value='__attribute__((format(printf,fmt,var)))'
2718                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2719                                 fi
2720                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2721                                 ;;
2722                         (scanf)
2723                                 cf_value='/* nothing */'
2724                                 if test "$cf_scanf_attribute" != no ; then
2725                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2726                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2727                                 fi
2728                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2729                                 ;;
2730                         (unused)
2731                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2732                                 ;;
2733                         esac
2734                 fi
2735         done
2736 else
2737         fgrep define conftest.i >>confdefs.h
2738 fi
2739 rm -rf conftest*
2740 fi
2741 ])dnl
2742 dnl ---------------------------------------------------------------------------
2743 dnl CF_GCC_VERSION version: 8 updated: 2019/09/07 13:38:36
2744 dnl --------------
2745 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
2746 dnl compatible), attempt to determine if icc/clang is actually used.
2747 AC_DEFUN([CF_GCC_VERSION],[
2748 AC_REQUIRE([AC_PROG_CC])
2749 GCC_VERSION=none
2750 if test "$GCC" = yes ; then
2751         AC_MSG_CHECKING(version of $CC)
2752         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2753         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2754         AC_MSG_RESULT($GCC_VERSION)
2755 fi
2756 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2757 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2758 ])dnl
2759 dnl ---------------------------------------------------------------------------
2760 dnl CF_GCC_WARNINGS version: 38 updated: 2020/08/28 15:08:28
2761 dnl ---------------
2762 dnl Check if the compiler supports useful warning options.  There's a few that
2763 dnl we don't use, simply because they're too noisy:
2764 dnl
2765 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2766 dnl     -Winline (usually not worthwhile)
2767 dnl     -Wredundant-decls (system headers make this too noisy)
2768 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2769 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2770 dnl             is enabled for ncurses using "--enable-const".
2771 dnl     -pedantic
2772 dnl
2773 dnl Parameter:
2774 dnl     $1 is an optional list of gcc warning flags that a particular
2775 dnl             application might want to use, e.g., "no-unused" for
2776 dnl             -Wno-unused
2777 dnl Special:
2778 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2779 dnl
2780 AC_DEFUN([CF_GCC_WARNINGS],
2781 [
2782 AC_REQUIRE([CF_GCC_VERSION])
2783 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
2784 cat > conftest.$ac_ext <<EOF
2785 #line __oline__ "${as_me:-configure}"
2786 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2787 EOF
2788 if test "$INTEL_COMPILER" = yes
2789 then
2790 # The "-wdXXX" options suppress warnings:
2791 # remark #1419: external declaration in primary source file
2792 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2793 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2794 # remark #193: zero used for undefined preprocessing identifier
2795 # remark #593: variable "curs_sb_left_arrow" was set but never used
2796 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2797 # remark #869: parameter "tw" was never referenced
2798 # remark #981: operands are evaluated in unspecified order
2799 # warning #279: controlling expression is constant
2800
2801         AC_CHECKING([for $CC warning options])
2802         cf_save_CFLAGS="$CFLAGS"
2803         EXTRA_CFLAGS="$EXTRA_CFLAGS -Wall"
2804         for cf_opt in \
2805                 wd1419 \
2806                 wd1683 \
2807                 wd1684 \
2808                 wd193 \
2809                 wd593 \
2810                 wd279 \
2811                 wd810 \
2812                 wd869 \
2813                 wd981
2814         do
2815                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2816                 if AC_TRY_EVAL(ac_compile); then
2817                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2818                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2819                 fi
2820         done
2821         CFLAGS="$cf_save_CFLAGS"
2822 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
2823 then
2824         AC_CHECKING([for $CC warning options])
2825         cf_save_CFLAGS="$CFLAGS"
2826         cf_warn_CONST=""
2827         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2828         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2829         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2830         for cf_opt in W Wall \
2831                 Wbad-function-cast \
2832                 Wcast-align \
2833                 Wcast-qual \
2834                 Wdeclaration-after-statement \
2835                 Wextra \
2836                 Winline \
2837                 Wmissing-declarations \
2838                 Wmissing-prototypes \
2839                 Wnested-externs \
2840                 Wpointer-arith \
2841                 Wshadow \
2842                 Wstrict-prototypes \
2843                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
2844         do
2845                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2846                 if AC_TRY_EVAL(ac_compile); then
2847                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2848                         case $cf_opt in
2849                         (Winline)
2850                                 case $GCC_VERSION in
2851                                 ([[34]].*)
2852                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2853                                         continue;;
2854                                 esac
2855                                 ;;
2856                         (Wpointer-arith)
2857                                 case $GCC_VERSION in
2858                                 ([[12]].*)
2859                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2860                                         continue;;
2861                                 esac
2862                                 ;;
2863                         esac
2864                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2865                 fi
2866         done
2867         CFLAGS="$cf_save_CFLAGS"
2868 fi
2869 rm -rf conftest*
2870
2871 AC_SUBST(EXTRA_CFLAGS)
2872 ])dnl
2873 dnl ---------------------------------------------------------------------------
2874 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2875 dnl ----------------
2876 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2877 dnl unistd.h or (nonstandard) in getopt.h
2878 AC_DEFUN([CF_GETOPT_HEADER],
2879 [
2880 AC_HAVE_HEADERS(unistd.h getopt.h)
2881 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2882 cf_cv_getopt_header=none
2883 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2884 do
2885 AC_TRY_COMPILE([
2886 #include <$cf_header>],
2887 [int x = optind; char *y = optarg],
2888 [cf_cv_getopt_header=$cf_header
2889  break])
2890 done
2891 ])
2892 if test $cf_cv_getopt_header != none ; then
2893         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2894 fi
2895 if test $cf_cv_getopt_header = getopt.h ; then
2896         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2897 fi
2898 ])dnl
2899 dnl ---------------------------------------------------------------------------
2900 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2901 dnl -----------------
2902 AC_DEFUN([CF_GNATPREP_OPT_T],[
2903 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2904 cf_cv_gnatprep_opt_t=no
2905 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2906 ])
2907 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2908 AC_SUBST(GNATPREP_OPTS)
2909 ])dnl
2910 dnl ---------------------------------------------------------------------------
2911 dnl CF_GNAT_GENERICS version: 6 updated: 2020/07/04 19:30:27
2912 dnl ----------------
2913 AC_DEFUN([CF_GNAT_GENERICS],
2914 [
2915 AC_REQUIRE([CF_GNAT_VERSION])
2916
2917 AC_MSG_CHECKING(if GNAT supports generics)
2918 case $cf_cv_gnat_version in
2919 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
2920         cf_gnat_generics=yes
2921         ;;
2922 (*)
2923         cf_gnat_generics=no
2924         ;;
2925 esac
2926 AC_MSG_RESULT($cf_gnat_generics)
2927
2928 if test "$cf_gnat_generics" = yes
2929 then
2930         cf_compile_generics=generics
2931         cf_generic_objects="\${GENOBJS}"
2932 else
2933         cf_compile_generics=
2934         cf_generic_objects=
2935 fi
2936
2937 AC_SUBST(cf_compile_generics)
2938 AC_SUBST(cf_generic_objects)
2939 ])dnl
2940 dnl ---------------------------------------------------------------------------
2941 dnl CF_GNAT_PROJECTS version: 10 updated: 2019/12/31 08:53:54
2942 dnl ----------------
2943 dnl GNAT projects are configured with ".gpr" project files.
2944 dnl GNAT libraries are a further development, using the project feature.
2945 AC_DEFUN([CF_GNAT_PROJECTS],
2946 [
2947 AC_REQUIRE([CF_GNAT_VERSION])
2948 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2949
2950 cf_gnat_libraries=no
2951 cf_gnat_projects=no
2952
2953 if test "$enable_gnat_projects" != no ; then
2954 AC_MSG_CHECKING(if GNAT supports project files)
2955 case $cf_cv_gnat_version in
2956 (3.[[0-9]]*)
2957         ;;
2958 (*)
2959         case $cf_cv_system_name in
2960         (cygwin*|msys*)
2961                 ;;
2962         (*)
2963                 rm -rf conftest* *~conftest*
2964                 if mkdir conftest.src conftest.bin conftest.lib
2965                 then
2966                         cd conftest.src
2967                         rm -rf conftest* *~conftest*
2968                         cat >>library.gpr <<CF_EOF
2969 project Library is
2970   Kind := External ("LIB_KIND");
2971   for Library_Name use "ConfTest";
2972   for Object_Dir use ".";
2973   for Library_ALI_Dir use External("LIBRARY_DIR");
2974   for Library_Version use External ("SONAME");
2975   for Library_Kind use Kind;
2976   for Library_Dir use External("BUILD_DIR");
2977   Source_Dir := External ("SOURCE_DIR");
2978   for Source_Dirs use (Source_Dir);
2979 end Library;
2980 CF_EOF
2981                         cat >>confpackage.ads <<CF_EOF
2982 package ConfPackage is
2983    procedure conftest;
2984 end ConfPackage;
2985 CF_EOF
2986                         cat >>confpackage.adb <<CF_EOF
2987 with Text_IO;
2988 package body ConfPackage is
2989    procedure conftest is
2990    begin
2991       Text_IO.Put ("Hello World");
2992       Text_IO.New_Line;
2993    end conftest;
2994 end ConfPackage;
2995 CF_EOF
2996                         if ( $cf_ada_make $ADAFLAGS \
2997                                         -Plibrary.gpr \
2998                                         -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2999                                         -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
3000                                         -XSOURCE_DIR=`pwd` \
3001                                         -XSONAME=libConfTest.so.1 \
3002                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
3003                                 cf_gnat_projects=yes
3004                         fi
3005                         cd ..
3006                 fi
3007                 if test -f conftest.lib/confpackage.ali
3008                 then
3009                         cf_gnat_libraries=yes
3010                 fi
3011                 rm -rf conftest* *~conftest*
3012                 ;;
3013         esac
3014         ;;
3015 esac
3016 AC_MSG_RESULT($cf_gnat_projects)
3017 fi # enable_gnat_projects
3018
3019 if test $cf_gnat_projects = yes
3020 then
3021         AC_MSG_CHECKING(if GNAT supports libraries)
3022         AC_MSG_RESULT($cf_gnat_libraries)
3023 fi
3024
3025 if test "$cf_gnat_projects" = yes
3026 then
3027         USE_OLD_MAKERULES="#"
3028         USE_GNAT_PROJECTS=""
3029 else
3030         USE_OLD_MAKERULES=""
3031         USE_GNAT_PROJECTS="#"
3032 fi
3033
3034 if test "$cf_gnat_libraries" = yes
3035 then
3036         USE_GNAT_LIBRARIES=""
3037 else
3038         USE_GNAT_LIBRARIES="#"
3039 fi
3040
3041 AC_SUBST(USE_OLD_MAKERULES)
3042 AC_SUBST(USE_GNAT_PROJECTS)
3043 AC_SUBST(USE_GNAT_LIBRARIES)
3044 ])dnl
3045 dnl ---------------------------------------------------------------------------
3046 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
3047 dnl --------------
3048 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
3049 dnl is noted that gnat may compile a tasking unit even for configurations which
3050 dnl fail at runtime.
3051 AC_DEFUN([CF_GNAT_SIGINT],[
3052 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
3053 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
3054
3055 package ConfTest is
3056
3057    pragma Warnings (Off);  --  the next pragma exists since 3.11p
3058    pragma Unreserve_All_Interrupts;
3059    pragma Warnings (On);
3060
3061    protected Process is
3062       procedure Stop;
3063       function Continue return Boolean;
3064       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
3065    private
3066       Done : Boolean := False;
3067    end Process;
3068
3069 end ConfTest;],
3070 [package body ConfTest is
3071    protected body Process is
3072       procedure Stop is
3073       begin
3074          Done := True;
3075       end Stop;
3076       function Continue return Boolean is
3077       begin
3078          return not Done;
3079       end Continue;
3080    end Process;
3081 end ConfTest;],
3082         [cf_cv_gnat_sigint=yes],
3083         [cf_cv_gnat_sigint=no])])
3084
3085 if test $cf_cv_gnat_sigint = yes ; then
3086         USE_GNAT_SIGINT=""
3087 else
3088         USE_GNAT_SIGINT="#"
3089 fi
3090 AC_SUBST(USE_GNAT_SIGINT)
3091 ])dnl
3092 dnl ---------------------------------------------------------------------------
3093 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
3094 dnl ----------------
3095 dnl Verify that a test program compiles/links with GNAT.
3096 dnl $cf_ada_make is set to the program that compiles/links
3097 dnl $ADAFLAGS may be set to the GNAT flags.
3098 dnl
3099 dnl $1 is the text of the spec
3100 dnl $2 is the text of the body
3101 dnl $3 is the shell command to execute if successful
3102 dnl $4 is the shell command to execute if not successful
3103 AC_DEFUN([CF_GNAT_TRY_LINK],
3104 [
3105 rm -rf conftest* *~conftest*
3106 cat >>conftest.ads <<CF_EOF
3107 $1
3108 CF_EOF
3109 cat >>conftest.adb <<CF_EOF
3110 $2
3111 CF_EOF
3112 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3113 ifelse($3,,      :,[      $3])
3114 ifelse($4,,,[else
3115    $4])
3116 fi
3117 rm -rf conftest* *~conftest*
3118 ])dnl
3119 dnl ---------------------------------------------------------------------------
3120 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
3121 dnl ---------------
3122 dnl Verify that a test program compiles and runs with GNAT
3123 dnl $cf_ada_make is set to the program that compiles/links
3124 dnl $ADAFLAGS may be set to the GNAT flags.
3125 dnl
3126 dnl $1 is the text of the spec
3127 dnl $2 is the text of the body
3128 dnl $3 is the shell command to execute if successful
3129 dnl $4 is the shell command to execute if not successful
3130 AC_DEFUN([CF_GNAT_TRY_RUN],
3131 [
3132 rm -rf conftest* *~conftest*
3133 cat >>conftest.ads <<CF_EOF
3134 $1
3135 CF_EOF
3136 cat >>conftest.adb <<CF_EOF
3137 $2
3138 CF_EOF
3139 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3140    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
3141 ifelse($3,,      :,[      $3])
3142 ifelse($4,,,[   else
3143       $4])
3144    fi
3145 ifelse($4,,,[else
3146    $4])
3147 fi
3148 rm -rf conftest* *~conftest*
3149 ])dnl
3150 dnl ---------------------------------------------------------------------------
3151 dnl CF_GNAT_VERSION version: 22 updated: 2019/12/31 08:53:54
3152 dnl ---------------
3153 dnl $1 = cache variable to update
3154 dnl $2 = program name
3155 dnl Verify version of GNAT or related tool
3156 AC_DEFUN([CF_GNAT_VERSION],
3157 [
3158 AC_CACHE_CHECK(for ifelse($2,,gnat,$2) version, cf_cv_gnat_version,[
3159 cf_cv_gnat_version=`ifelse($2,,${cf_ada_make:-gnatmake},$2) --version 2>&1 | \
3160         grep '[[0-9]].[[0-9]][[0-9]]*' |\
3161         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
3162 ])
3163 test -z "$cf_cv_gnat_version" && cf_cv_gnat_version=no
3164 ifelse($1,,,[eval $1=$cf_cv_gnat_version; unset cf_cv_gnat_version])
3165 ])dnl
3166 dnl ---------------------------------------------------------------------------
3167 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
3168 dnl -------------
3169 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
3170 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
3171 dnl (or misfeature) of glibc2, which breaks portability of many applications,
3172 dnl since it is interwoven with GNU extensions.
3173 dnl
3174 dnl Well, yes we could work around it...
3175 dnl
3176 dnl Parameters:
3177 dnl     $1 is the nominal value for _XOPEN_SOURCE
3178 AC_DEFUN([CF_GNU_SOURCE],
3179 [
3180 cf_gnu_xopen_source=ifelse($1,,500,$1)
3181
3182 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
3183 AC_TRY_COMPILE([#include <sys/types.h>],[
3184         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
3185                 return 0;
3186         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
3187                 return 0;
3188         #else
3189         #       error not GNU C library
3190         #endif],
3191         [cf_cv_gnu_library=yes],
3192         [cf_cv_gnu_library=no])
3193 ])
3194
3195 if test x$cf_cv_gnu_library = xyes; then
3196
3197         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
3198         # was changed to help a little.  newlib incorporated the change about 4
3199         # years later.
3200         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
3201                 cf_save="$CPPFLAGS"
3202                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3203                 AC_TRY_COMPILE([#include <sys/types.h>],[
3204                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
3205                                 return 0;
3206                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
3207                                 return 0;
3208                         #else
3209                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
3210                         #endif],
3211                         [cf_cv_gnu_library_219=yes],
3212                         [cf_cv_gnu_library_219=no])
3213                 CPPFLAGS="$cf_save"
3214         ])
3215
3216         if test "x$cf_cv_gnu_library_219" = xyes; then
3217                 cf_save="$CPPFLAGS"
3218                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
3219                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
3220                         AC_TRY_COMPILE([
3221                                 #include <limits.h>
3222                                 #include <sys/types.h>
3223                                 ],[
3224                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
3225                                         return 0;
3226                                 #else
3227                                 #       error GNU C library is too old
3228                                 #endif],
3229                                 [cf_cv_gnu_dftsrc_219=yes],
3230                                 [cf_cv_gnu_dftsrc_219=no])
3231                         ])
3232                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
3233         else
3234                 cf_cv_gnu_dftsrc_219=maybe
3235         fi
3236
3237         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
3238
3239                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
3240                 AC_TRY_COMPILE([#include <sys/types.h>],[
3241                         #ifndef _XOPEN_SOURCE
3242                         #error  expected _XOPEN_SOURCE to be defined
3243                         #endif],
3244                         [cf_cv_gnu_source=no],
3245                         [cf_save="$CPPFLAGS"
3246                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
3247                          AC_TRY_COMPILE([#include <sys/types.h>],[
3248                                 #ifdef _XOPEN_SOURCE
3249                                 #error  expected _XOPEN_SOURCE to be undefined
3250                                 #endif],
3251                                 [cf_cv_gnu_source=no],
3252                                 [cf_cv_gnu_source=yes])
3253                         CPPFLAGS="$cf_save"
3254                         ])
3255                 ])
3256
3257                 if test "$cf_cv_gnu_source" = yes
3258                 then
3259                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
3260                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
3261                         AC_TRY_COMPILE([#include <sys/types.h>],[
3262                                 #ifdef _DEFAULT_SOURCE
3263                                 #error  expected _DEFAULT_SOURCE to be undefined
3264                                 #endif],
3265                                 [cf_cv_default_source=no],
3266                                 [cf_cv_default_source=yes])
3267                         ])
3268                         if test "$cf_cv_default_source" = yes
3269                         then
3270                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3271                         fi
3272                 fi
3273         fi
3274
3275 fi
3276 ])dnl
3277 dnl ---------------------------------------------------------------------------
3278 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
3279 dnl --------------
3280 dnl If we're trying to use g++, test if libg++ is installed (a rather common
3281 dnl problem :-).  If we have the compiler but no library, we'll be able to
3282 dnl configure, but won't be able to build the c++ demo program.
3283 AC_DEFUN([CF_GPP_LIBRARY],
3284 [
3285 cf_cxx_library=unknown
3286 case $cf_cv_system_name in
3287 (os2*)
3288         cf_gpp_libname=gpp
3289         ;;
3290 (*)
3291         cf_gpp_libname=g++
3292         ;;
3293 esac
3294 if test "$GXX" = yes; then
3295         AC_MSG_CHECKING([for lib$cf_gpp_libname])
3296         cf_save="$LIBS"
3297         CF_ADD_LIB($cf_gpp_libname)
3298         AC_TRY_LINK([
3299 #include <$cf_gpp_libname/builtin.h>
3300         ],
3301         [two_arg_error_handler_t foo2 = lib_error_handler],
3302         [cf_cxx_library=yes
3303          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3304          if test "$cf_gpp_libname" = cpp ; then
3305             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
3306          else
3307             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
3308          fi],
3309         [AC_TRY_LINK([
3310 #include <builtin.h>
3311         ],
3312         [two_arg_error_handler_t foo2 = lib_error_handler],
3313         [cf_cxx_library=yes
3314          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3315          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
3316         [cf_cxx_library=no])])
3317         LIBS="$cf_save"
3318         AC_MSG_RESULT($cf_cxx_library)
3319 fi
3320 ])dnl
3321 dnl ---------------------------------------------------------------------------
3322 dnl CF_GXX_VERSION version: 8 updated: 2017/02/11 14:48:57
3323 dnl --------------
3324 dnl Check for version of g++
3325 AC_DEFUN([CF_GXX_VERSION],[
3326 AC_REQUIRE([AC_PROG_CPP])
3327 GXX_VERSION=none
3328 if test "$GXX" = yes; then
3329         AC_MSG_CHECKING(version of ${CXX:-g++})
3330         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
3331         if test -z "$GXX_VERSION"
3332         then
3333                 GXX_VERSION=unknown
3334                 GXX=no
3335         fi
3336         AC_MSG_RESULT($GXX_VERSION)
3337 fi
3338 ])dnl
3339 dnl ---------------------------------------------------------------------------
3340 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
3341 dnl ---------------
3342 dnl Check if the compiler supports useful warning options.
3343 dnl
3344 dnl Most of gcc's options apply to g++, except:
3345 dnl     -Wbad-function-cast
3346 dnl     -Wmissing-declarations
3347 dnl     -Wnested-externs
3348 dnl
3349 dnl Omit a few (for now):
3350 dnl     -Winline
3351 dnl
3352 dnl Parameter:
3353 dnl     $1 is an optional list of g++ warning flags that a particular
3354 dnl             application might want to use, e.g., "no-unused" for
3355 dnl             -Wno-unused
3356 dnl Special:
3357 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
3358 dnl
3359 AC_DEFUN([CF_GXX_WARNINGS],
3360 [
3361
3362 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
3363 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
3364
3365 AC_REQUIRE([CF_GXX_VERSION])
3366
3367 AC_LANG_SAVE
3368 AC_LANG_CPLUSPLUS
3369
3370 cat > conftest.$ac_ext <<EOF
3371 #line __oline__ "configure"
3372 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
3373 EOF
3374
3375 if test "$INTEL_CPLUSPLUS" = yes
3376 then
3377 # The "-wdXXX" options suppress warnings:
3378 # remark #1419: external declaration in primary source file
3379 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3380 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3381 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
3382 # remark #193: zero used for undefined preprocessing identifier
3383 # remark #593: variable "curs_sb_left_arrow" was set but never used
3384 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
3385 # remark #869: parameter "tw" was never referenced
3386 # remark #981: operands are evaluated in unspecified order
3387 # warning #269: invalid format string conversion
3388
3389         AC_CHECKING([for $CC warning options])
3390         cf_save_CXXFLAGS="$CXXFLAGS"
3391         EXTRA_CXXFLAGS="-Wall"
3392         for cf_opt in \
3393                 wd1419 \
3394                 wd1682 \
3395                 wd1683 \
3396                 wd1684 \
3397                 wd193 \
3398                 wd279 \
3399                 wd593 \
3400                 wd810 \
3401                 wd869 \
3402                 wd981
3403         do
3404                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
3405                 if AC_TRY_EVAL(ac_compile); then
3406                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3407                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3408                 fi
3409         done
3410         CXXFLAGS="$cf_save_CXXFLAGS"
3411
3412 elif test "$GXX" = yes
3413 then
3414         AC_CHECKING([for $CXX warning options])
3415         cf_save_CXXFLAGS="$CXXFLAGS"
3416         EXTRA_CXXFLAGS="-W -Wall"
3417         cf_gxx_extra_warnings=""
3418         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
3419         case "$GCC_VERSION" in
3420         ([[1-2]].*)
3421                 ;;
3422         (*)
3423                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
3424                 ;;
3425         esac
3426         for cf_opt in \
3427                 Wabi \
3428                 fabi-version=0 \
3429                 Wextra \
3430                 Wignored-qualifiers \
3431                 Wlogical-op \
3432                 Woverloaded-virtual \
3433                 Wsign-promo \
3434                 Wsynth \
3435                 Wold-style-cast \
3436                 Wcast-align \
3437                 Wcast-qual \
3438                 Wpointer-arith \
3439                 Wshadow \
3440                 Wundef $cf_gxx_extra_warnings $1
3441         do
3442                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
3443                 if AC_TRY_EVAL(ac_compile); then
3444                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3445                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3446                 else
3447                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
3448                 fi
3449         done
3450         CXXFLAGS="$cf_save_CXXFLAGS"
3451 fi
3452
3453 rm -rf conftest*
3454 AC_LANG_RESTORE
3455 AC_SUBST(EXTRA_CXXFLAGS)
3456 ])dnl
3457 dnl ---------------------------------------------------------------------------
3458 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
3459 dnl ------------
3460 dnl Look for an instance of the Berkeley hashed database.
3461 dnl
3462 dnl $1 = optional parameter, to specify install-prefix for the database.
3463 AC_DEFUN([CF_HASHED_DB],
3464 [
3465 ifelse([$1],,,[
3466 case $1 in
3467 (yes|*able*)
3468         ;;
3469 (*)
3470         if test -d "$1" ; then
3471                 CF_ADD_INCDIR($1/include)
3472                 CF_ADD_LIBDIR($1/lib)
3473         else
3474                 case "$1" in
3475                 (./*|../*|/*)
3476                         AC_MSG_WARN(no such directory $1)
3477                         ;;
3478                 (*)
3479                         CF_FIND_SUB_INCDIR($1)
3480                         CF_FIND_SUB_LIBDIR($1)
3481                         ;;
3482                 esac
3483         fi
3484 esac
3485 ])
3486 AC_CHECK_HEADER(db.h,[
3487 CF_HASHED_DB_VERSION
3488 if test "$cf_cv_hashed_db_version" = unknown ; then
3489         AC_MSG_ERROR(Cannot determine version of db)
3490 else
3491         CF_HASHED_DB_LIBS
3492         if test "$cf_cv_hashed_db_libs" = unknown ; then
3493                 AC_MSG_ERROR(Cannot determine library for db)
3494         elif test "$cf_cv_hashed_db_libs" != default ; then
3495                 CF_ADD_LIB($cf_cv_hashed_db_libs)
3496         fi
3497 fi
3498 ],[
3499         AC_MSG_ERROR(Cannot find db.h)
3500 ])
3501 ])dnl
3502 dnl ---------------------------------------------------------------------------
3503 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
3504 dnl -----------------
3505 dnl Given that we have the header and version for hashed database, find the
3506 dnl library information.
3507 AC_DEFUN([CF_HASHED_DB_LIBS],
3508 [
3509 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
3510 cf_cv_hashed_db_libs=unknown
3511 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
3512 do
3513         cf_save_libs="$LIBS"
3514         if test -n "$cf_db_libs"; then
3515                 CF_ADD_LIB($cf_db_libs)
3516         fi
3517         CF_MSG_LOG(checking for library "$cf_db_libs")
3518         AC_TRY_LINK([
3519 $ac_includes_default
3520 #include <db.h>
3521 ],[
3522         char *path = "/tmp/foo";
3523 #ifdef DB_VERSION_MAJOR
3524 #if DB_VERSION_MAJOR >= 4
3525         DB *result = 0;
3526         db_create(&result, NULL, 0);
3527         result->open(result,
3528                 NULL,
3529                 path,
3530                 path,
3531                 DB_HASH,
3532                 DB_CREATE,
3533                 0644);
3534 #elif DB_VERSION_MAJOR >= 3
3535         DB *result = 0;
3536         db_create(&result, NULL, 0);
3537         result->open(result,
3538                 path,
3539                 path,
3540                 DB_HASH,
3541                 DB_CREATE,
3542                 0644);
3543 #elif DB_VERSION_MAJOR >= 2
3544         DB *result = 0;
3545         db_open(path,
3546                 DB_HASH,
3547                 DB_CREATE,
3548                 0644,
3549                 (DB_ENV *) 0,
3550                 (DB_INFO *) 0,
3551                 &result);
3552 #endif /* DB_VERSION_MAJOR */
3553 #else
3554         DB *result = dbopen(path,
3555                      2,
3556                      0644,
3557                      DB_HASH,
3558                      0);
3559 #endif
3560         ${cf_cv_main_return:-return}(result != 0)
3561 ],[
3562         if test -n "$cf_db_libs" ; then
3563                 cf_cv_hashed_db_libs=$cf_db_libs
3564         else
3565                 cf_cv_hashed_db_libs=default
3566         fi
3567         LIBS="$cf_save_libs"
3568         break
3569 ])
3570         LIBS="$cf_save_libs"
3571 done
3572 ])
3573 ])dnl
3574 dnl ---------------------------------------------------------------------------
3575 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3576 dnl --------------------
3577 dnl Given that we have the header file for hashed database, find the version
3578 dnl information.
3579 AC_DEFUN([CF_HASHED_DB_VERSION],
3580 [
3581 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3582 cf_cv_hashed_db_version=unknown
3583
3584 for cf_db_version in 1 2 3 4 5 6
3585 do
3586         CF_MSG_LOG(checking for db version $cf_db_version)
3587         AC_TRY_COMPILE([
3588 $ac_includes_default
3589 #include <db.h>
3590
3591 #ifdef DB_VERSION_MAJOR
3592         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3593 #if $cf_db_version == DB_VERSION_MAJOR
3594         /* ok */
3595 #else
3596         make an error
3597 #endif
3598 #else
3599 #if $cf_db_version == 1
3600         /* ok: assuming this is DB 1.8.5 */
3601 #else
3602         make an error
3603 #endif
3604 #endif
3605 ],[DBT *foo = 0],[
3606         cf_cv_hashed_db_version=$cf_db_version
3607         break
3608         ])
3609 done
3610 ])
3611 ])dnl
3612 dnl ---------------------------------------------------------------------------
3613 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
3614 dnl --------------
3615 dnl Construct a search-list of directories for a nonstandard header-file
3616 dnl
3617 dnl Parameters
3618 dnl     $1 = the variable to return as result
3619 dnl     $2 = the package name
3620 AC_DEFUN([CF_HEADER_PATH],
3621 [
3622 $1=
3623
3624 # collect the current set of include-directories from compiler flags
3625 cf_header_path_list=""
3626 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3627         for cf_header_path in $CPPFLAGS $CFLAGS
3628         do
3629                 case $cf_header_path in
3630                 (-I*)
3631                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3632                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3633                         cf_header_path_list="$cf_header_path_list [$]$1"
3634                         ;;
3635                 esac
3636         done
3637 fi
3638
3639 # add the variations for the package we are looking for
3640 CF_SUBDIR_PATH($1,$2,include)
3641
3642 test "$includedir" != NONE && \
3643 test "$includedir" != "/usr/include" && \
3644 test -d "$includedir" && {
3645         test -d $includedir &&    $1="[$]$1 $includedir"
3646         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
3647 }
3648
3649 test "$oldincludedir" != NONE && \
3650 test "$oldincludedir" != "/usr/include" && \
3651 test -d "$oldincludedir" && {
3652         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
3653         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
3654 }
3655
3656 $1="[$]$1 $cf_header_path_list"
3657 ])dnl
3658 dnl ---------------------------------------------------------------------------
3659 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
3660 dnl ---------------
3661 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3662 AC_DEFUN([CF_HELP_MESSAGE],
3663 [CF_ACVERSION_CHECK(2.53,[],[
3664 AC_DIVERT_HELP($1)])dnl
3665 ])dnl
3666 dnl ---------------------------------------------------------------------------
3667 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3668 dnl ---------------
3669 dnl Construct the list of include-options according to whether we're building
3670 dnl in the source directory or using '--srcdir=DIR' option.
3671 AC_DEFUN([CF_INCLUDE_DIRS],
3672 [
3673 if test "$srcdir" != "."; then
3674         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3675 fi
3676 CPPFLAGS="-I../include $CPPFLAGS"
3677 if test "$srcdir" != "."; then
3678         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3679 fi
3680 CPPFLAGS="-I. $CPPFLAGS"
3681 AC_SUBST(CPPFLAGS)
3682 ])dnl
3683 dnl ---------------------------------------------------------------------------
3684 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
3685 dnl ---------------
3686 dnl prompt for/fill-in useful install-program options
3687 AC_DEFUN([CF_INSTALL_OPTS],
3688 [
3689 CF_INSTALL_OPT_S
3690 CF_INSTALL_OPT_P
3691 CF_INSTALL_OPT_O
3692 ])dnl
3693 dnl ---------------------------------------------------------------------------
3694 dnl CF_INSTALL_OPT_O version: 2 updated: 2015/05/15 19:45:35
3695 dnl ----------------
3696 dnl Almost all "install" programs default to the current user's ownership.
3697 dnl Almost - MINIX is an exception.
3698 AC_DEFUN([CF_INSTALL_OPT_O],
3699 [
3700 AC_MSG_CHECKING(if install needs to be told about ownership)
3701 case `$ac_config_guess` in
3702 (*minix)
3703         with_install_o=yes
3704         ;;
3705 (*)
3706         with_install_o=no
3707         ;;
3708 esac
3709
3710 AC_MSG_RESULT($with_install_o)
3711 if test "x$with_install_o" = xyes
3712 then
3713         INSTALL_OPT_O=`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`
3714 else
3715         INSTALL_OPT_O=
3716 fi
3717
3718 AC_SUBST(INSTALL_OPT_O)
3719 ])dnl
3720 dnl ---------------------------------------------------------------------------
3721 dnl CF_INSTALL_OPT_P version: 1 updated: 2018/08/18 12:19:21
3722 dnl ----------------
3723 dnl Some install-programs accept a "-p" option to preserve file modification
3724 dnl timestamps.  That can be useful as an install option, as well as a way to
3725 dnl avoid the need for ranlib after copying a static archive.
3726 AC_DEFUN([CF_INSTALL_OPT_P],
3727 [
3728 : ${INSTALL:=install}
3729 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
3730         rm -rf conftest*
3731         date >conftest.in
3732         mkdir conftest.out
3733         sleep 3
3734         if $INSTALL -p conftest.in conftest.out 2>/dev/null
3735         then
3736                 if test -f conftest.out/conftest.in
3737                 then
3738                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
3739                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
3740                         if test -s conftest.err
3741                         then
3742                                 cf_cv_install_p=no
3743                         else
3744                                 cf_cv_install_p=yes
3745                         fi
3746                 else
3747                         cf_cv_install_p=no
3748                 fi
3749         else
3750                 cf_cv_install_p=no
3751         fi
3752         rm -rf conftest*
3753 ])
3754 ])dnl
3755 dnl ---------------------------------------------------------------------------
3756 dnl CF_INSTALL_OPT_S version: 2 updated: 2018/08/18 12:19:21
3757 dnl ----------------
3758 dnl By default, we should strip executables which are installed, but leave the
3759 dnl ability to suppress that for unit-testing.
3760 AC_DEFUN([CF_INSTALL_OPT_S],
3761 [
3762 AC_MSG_CHECKING(if you want to install stripped executables)
3763 CF_ARG_DISABLE(stripping,
3764         [  --disable-stripping     do not strip (debug info) installed executables],
3765         [with_stripping=no],
3766         [with_stripping=yes])
3767 AC_MSG_RESULT($with_stripping)
3768
3769 if test "$with_stripping" = yes
3770 then
3771         INSTALL_OPT_S="-s"
3772 else
3773         INSTALL_OPT_S=
3774 fi
3775 AC_SUBST(INSTALL_OPT_S)
3776 ])dnl
3777 dnl ---------------------------------------------------------------------------
3778 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
3779 dnl -----------------
3780 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3781 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3782 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3783 dnl
3784 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3785 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3786 dnl the wrappers for gcc and g++ warnings.
3787 dnl
3788 dnl $1 = GCC (default) or GXX
3789 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3790 dnl $3 = CFLAGS (default) or CXXFLAGS
3791 AC_DEFUN([CF_INTEL_COMPILER],[
3792 AC_REQUIRE([AC_CANONICAL_HOST])
3793 ifelse([$2],,INTEL_COMPILER,[$2])=no
3794
3795 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3796         case $host_os in
3797         (linux*|gnu*)
3798                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3799                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3800                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3801                 AC_TRY_COMPILE([],[
3802 #ifdef __INTEL_COMPILER
3803 #else
3804 make an error
3805 #endif
3806 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3807 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3808 ],[])
3809                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3810                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3811                 ;;
3812         esac
3813 fi
3814 ])dnl
3815 dnl ---------------------------------------------------------------------------
3816 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3817 dnl ----------
3818 dnl Check if we have either a function or macro for 'isascii()'.
3819 AC_DEFUN([CF_ISASCII],
3820 [
3821 AC_MSG_CHECKING(for isascii)
3822 AC_CACHE_VAL(cf_cv_have_isascii,[
3823         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3824         [cf_cv_have_isascii=yes],
3825         [cf_cv_have_isascii=no])
3826 ])dnl
3827 AC_MSG_RESULT($cf_cv_have_isascii)
3828 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3829 ])dnl
3830 dnl ---------------------------------------------------------------------------
3831 dnl CF_LARGEFILE version: 12 updated: 2020/03/19 20:23:48
3832 dnl ------------
3833 dnl Add checks for large file support.
3834 AC_DEFUN([CF_LARGEFILE],[
3835 ifdef([AC_FUNC_FSEEKO],[
3836         AC_SYS_LARGEFILE
3837         if test "$enable_largefile" != no ; then
3838         AC_FUNC_FSEEKO
3839
3840         # Normally we would collect these definitions in the config.h,
3841         # but (like _XOPEN_SOURCE), some environments rely on having these
3842         # defined before any of the system headers are included.  Another
3843         # case comes up with C++, e.g., on AIX the compiler compiles the
3844         # header files by themselves before looking at the body files it is
3845         # told to compile.  For ncurses, those header files do not include
3846         # the config.h
3847         if test "$ac_cv_sys_large_files" != no
3848         then
3849                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
3850         fi
3851         if test "$ac_cv_sys_largefile_source" != no
3852         then
3853                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
3854         fi
3855         if test "$ac_cv_sys_file_offset_bits" != no
3856         then
3857                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
3858         fi
3859
3860         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3861                 AC_TRY_COMPILE([
3862 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
3863 #include <sys/types.h>
3864 #include <dirent.h>
3865                 ],[
3866                 /* if transitional largefile support is setup, this is true */
3867                 extern struct dirent64 * readdir(DIR *);
3868                 struct dirent64 *x = readdir((DIR *)0);
3869                 struct dirent *y = readdir((DIR *)0);
3870                 int z = x - y;
3871                 (void)z;
3872                 ],
3873                 [cf_cv_struct_dirent64=yes],
3874                 [cf_cv_struct_dirent64=no])
3875         ])
3876         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3877         fi
3878 ])
3879 ])
3880 dnl ---------------------------------------------------------------------------
3881 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3882 dnl -----------------
3883 dnl Check for compiler/linker flags used to temporarily force usage of static
3884 dnl libraries.  This depends on the compiler and platform.  Use this to help
3885 dnl ensure that the linker picks up a given library based on its position in
3886 dnl the list of linker options and libraries.
3887 AC_DEFUN([CF_LDFLAGS_STATIC],[
3888
3889 if test "$GCC" = yes ; then
3890         case $cf_cv_system_name in
3891         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3892                 LDFLAGS_STATIC=
3893                 LDFLAGS_SHARED=
3894                 ;;
3895         (*)     # normally, except when broken
3896                 LDFLAGS_STATIC=-static
3897                 LDFLAGS_SHARED=-dynamic
3898                 ;;
3899         esac
3900 else
3901         case $cf_cv_system_name in
3902         (aix[[4-7]]*)   # from ld manpage
3903                 LDFLAGS_STATIC=-bstatic
3904                 LDFLAGS_SHARED=-bdynamic
3905                 ;;
3906         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3907                 # We could also use just "archive" and "shared".
3908                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3909                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3910                 ;;
3911         (irix*)         # from ld manpage IRIX64
3912                 LDFLAGS_STATIC=-Bstatic
3913                 LDFLAGS_SHARED=-Bdynamic
3914                 ;;
3915         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3916                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3917                 LDFLAGS_STATIC=-noso
3918                 LDFLAGS_SHARED=-so_archive
3919                 ;;
3920         (solaris2*)
3921                 LDFLAGS_STATIC=-Bstatic
3922                 LDFLAGS_SHARED=-Bdynamic
3923                 ;;
3924         esac
3925 fi
3926
3927 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3928 then
3929         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3930
3931         rm -f libconftest.a
3932         cat >conftest.$ac_ext <<EOF
3933 #line __oline__ "configure"
3934 #include <stdio.h>
3935 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3936 EOF
3937         if AC_TRY_EVAL(ac_compile) ; then
3938                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3939                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3940         fi
3941         rm -f conftest.*
3942
3943         cf_save_LIBS="$LIBS"
3944
3945         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3946         AC_TRY_LINK([
3947 #line __oline__ "configure"
3948 #include <stdio.h>
3949 int cf_ldflags_static(FILE *fp);
3950 ],[
3951         return cf_ldflags_static(stdin);
3952 ],[
3953         # some linkers simply ignore the -dynamic
3954         case x`file conftest$ac_exeext 2>/dev/null` in
3955         (*static*)
3956                 cf_ldflags_static=no
3957                 ;;
3958         (*)
3959                 cf_ldflags_static=yes
3960                 ;;
3961         esac
3962 ],[cf_ldflags_static=no])
3963
3964         rm -f libconftest.*
3965         LIBS="$cf_save_LIBS"
3966
3967         AC_MSG_RESULT($cf_ldflags_static)
3968
3969         if test $cf_ldflags_static != yes
3970         then
3971                 LDFLAGS_STATIC=
3972                 LDFLAGS_SHARED=
3973         fi
3974 else
3975         LDFLAGS_STATIC=
3976         LDFLAGS_SHARED=
3977 fi
3978
3979 AC_SUBST(LDFLAGS_STATIC)
3980 AC_SUBST(LDFLAGS_SHARED)
3981 ])
3982 dnl ---------------------------------------------------------------------------
3983 dnl CF_LD_RPATH_OPT version: 8 updated: 2018/08/18 16:36:35
3984 dnl ---------------
3985 dnl For the given system and compiler, find the compiler flags to pass to the
3986 dnl loader to use the "rpath" feature.
3987 AC_DEFUN([CF_LD_RPATH_OPT],
3988 [
3989 AC_REQUIRE([CF_CHECK_CACHE])
3990
3991 LD_RPATH_OPT=
3992 if test "x$cf_cv_enable_rpath" != xno
3993 then
3994         AC_MSG_CHECKING(for an rpath option)
3995         case $cf_cv_system_name in
3996         (irix*)
3997                 if test "$GCC" = yes; then
3998                         LD_RPATH_OPT="-Wl,-rpath,"
3999                 else
4000                         LD_RPATH_OPT="-rpath "
4001                 fi
4002                 ;;
4003         (linux*|gnu*|k*bsd*-gnu|freebsd*)
4004                 LD_RPATH_OPT="-Wl,-rpath,"
4005                 ;;
4006         (openbsd[[2-9]].*|mirbsd*)
4007                 LD_RPATH_OPT="-Wl,-rpath,"
4008                 ;;
4009         (dragonfly*)
4010                 LD_RPATH_OPT="-rpath "
4011                 ;;
4012         (netbsd*)
4013                 LD_RPATH_OPT="-Wl,-rpath,"
4014                 ;;
4015         (osf*|mls+*)
4016                 LD_RPATH_OPT="-rpath "
4017                 ;;
4018         (solaris2*)
4019                 LD_RPATH_OPT="-R"
4020                 ;;
4021         (*)
4022                 ;;
4023         esac
4024         AC_MSG_RESULT($LD_RPATH_OPT)
4025
4026         case "x$LD_RPATH_OPT" in
4027         (x-R*)
4028                 AC_MSG_CHECKING(if we need a space after rpath option)
4029                 cf_save_LIBS="$LIBS"
4030                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
4031                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
4032                 LIBS="$cf_save_LIBS"
4033                 AC_MSG_RESULT($cf_rpath_space)
4034                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
4035                 ;;
4036         esac
4037 fi
4038 ])dnl
4039 dnl ---------------------------------------------------------------------------
4040 dnl CF_LD_SEARCHPATH version: 2 updated: 2019/09/26 20:34:14
4041 dnl ----------------
4042 dnl Try to obtain the linker's search-path, for use in scripts.
4043 dnl
4044 dnl Ignore LD_LIBRARY_PATH, etc.
4045 AC_DEFUN([CF_LD_SEARCHPATH],[
4046 AC_CACHE_CHECK(for linker search path,cf_cv_ld_searchpath,[
4047
4048 if test "$cross_compiling" != yes ; then
4049
4050 # GNU binutils' ld does not involve permissions which may stop ldconfig.
4051 cf_pathlist=`ld --verbose 2>/dev/null | grep SEARCH_DIR | sed -e 's,SEARCH_DIR[[("=]][[("=]]*,,g' -e 's/"[[)]];//gp' | sort -u`
4052
4053 # The -NX options tell newer versions of Linux ldconfig to not attempt to
4054 # update the cache, which makes it run faster.
4055 test -z "$cf_pathlist" && \
4056         cf_pathlist=`ldconfig -NX -v 2>/dev/null | sed -e '/^[[         ]]/d' -e 's/:$//' | sort -u`
4057
4058 test -z "$cf_pathlist" &&
4059         cf_pathlist=`ldconfig -v 2>/dev/null | sed -n -e '/^[[  ]]/d' -e 's/:$//p' | sort -u`
4060
4061 # This works with OpenBSD 6.5, which lists only filenames
4062 test -z "$cf_pathlist" &&
4063         cf_pathlist=`ldconfig -v 2>/dev/null | sed -n -e 's,^Adding \(.*\)/.*[$],\1,p' | sort -u`
4064
4065 if test -z "$cf_pathlist"
4066 then
4067         # dyld default path with MacOS
4068         if test -f /usr/bin/otool && test "x`uname -s`" = xDarwin
4069         then
4070                 # do this to bypass check
4071                 cf_cv_ld_searchpath='$HOME/lib'
4072                 cf_pathlist="/usr/local/lib /lib /usr/lib"
4073         fi
4074 fi
4075
4076 if test -z "$cf_pathlist"
4077 then
4078         # Solaris is hardcoded
4079         if test -d /opt/SUNWspro/lib
4080         then
4081                 cf_pathlist="/opt/SUNWspro/lib /usr/ccs/lib /usr/lib"
4082         elif test -d /usr/ccs/lib
4083         then
4084                 cf_pathlist="/usr/ccs/lib /usr/lib"
4085         fi
4086 fi
4087
4088 fi
4089
4090 # If nothing else, assume it is conventional
4091 test -z "$cf_pathlist" && cf_pathlist="/usr/lib /lib"
4092
4093 # Finally, check that this is only directories
4094 for cf_path in [$]0 $cf_pathlist
4095 do
4096         if test -d "$cf_path"; then
4097                 test -n "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath="${cf_cv_ld_searchpath} "
4098                 cf_cv_ld_searchpath="${cf_cv_ld_searchpath}${cf_path}"
4099         fi
4100 done
4101
4102 # Ensure that it is nonempty
4103 test -z "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath=/usr/lib
4104 ])
4105
4106 LD_SEARCHPATH=`echo "$cf_cv_ld_searchpath"|sed -e 's/ /|/g'`
4107 AC_SUBST(LD_SEARCHPATH)
4108 ])dnl
4109 dnl ---------------------------------------------------------------------------
4110 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
4111 dnl ---------------
4112 dnl Construct a search-list of directories for a nonstandard library-file
4113 dnl
4114 dnl Parameters
4115 dnl     $1 = the variable to return as result
4116 dnl     $2 = the package name
4117 AC_DEFUN([CF_LIBRARY_PATH],
4118 [
4119 $1=
4120 cf_library_path_list=""
4121 if test -n "${LDFLAGS}${LIBS}" ; then
4122         for cf_library_path in $LDFLAGS $LIBS
4123         do
4124                 case $cf_library_path in
4125                 (-L*)
4126                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
4127                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
4128                         cf_library_path_list="$cf_library_path_list [$]$1"
4129                         ;;
4130                 esac
4131         done
4132 fi
4133
4134 CF_SUBDIR_PATH($1,$2,lib)
4135
4136 $1="$cf_library_path_list [$]$1"
4137 ])dnl
4138 dnl ---------------------------------------------------------------------------
4139 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
4140 dnl ------------------
4141 AC_DEFUN([CF_LIBTOOL_VERSION],[
4142 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
4143 then
4144         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
4145 else
4146         cf_cv_libtool_version=
4147 fi
4148 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
4149 ])dnl
4150 dnl ---------------------------------------------------------------------------
4151 dnl CF_LIB_PREFIX version: 13 updated: 2020/04/04 10:11:47
4152 dnl -------------
4153 dnl Compute the library-prefix for the given host system
4154 dnl $1 = variable to set
4155 define([CF_LIB_PREFIX],
4156 [
4157         case $cf_cv_system_name in
4158         (OS/2*|os2*)
4159                 if test "$DFT_LWR_MODEL" = libtool; then
4160                         LIB_PREFIX='lib'
4161                 else
4162                         LIB_PREFIX=''
4163                 fi
4164                 ;;
4165         (*-msvc*)
4166                 LIB_PREFIX=''
4167                 ;;
4168         (*)     LIB_PREFIX='lib'
4169                 ;;
4170         esac
4171 ifelse($1,,,[$1=$LIB_PREFIX])
4172         AC_SUBST(LIB_PREFIX)
4173 ])dnl
4174 dnl ---------------------------------------------------------------------------
4175 dnl CF_LIB_RULES version: 90 updated: 2020/04/04 10:11:47
4176 dnl ------------
4177 dnl Append definitions and rules for the given models to the subdirectory
4178 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
4179 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
4180 dnl the corresponding makefile to list the models that we'll generate.
4181 dnl
4182 dnl For shared libraries, make a list of symbolic links to construct when
4183 dnl generating each library.  The convention used for Linux is the simplest
4184 dnl one:
4185 dnl     lib<name>.so    ->
4186 dnl     lib<name>.so.<major>    ->
4187 dnl     lib<name>.so.<maj>.<minor>
4188 dnl
4189 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
4190 AC_DEFUN([CF_LIB_RULES],
4191 [
4192 cf_prefix=$LIB_PREFIX
4193 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
4194
4195 case $cf_cv_shlib_version in
4196 (cygdll|msysdll|mingw|msvcdll)
4197         TINFO_NAME=$TINFO_ARG_SUFFIX
4198         TINFO_SUFFIX=.dll
4199         ;;
4200 esac
4201
4202 if test -n "$TINFO_SUFFIX" ; then
4203         case $TINFO_SUFFIX in
4204         (tw*)
4205                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
4206                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
4207                 ;;
4208         (t*)
4209                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
4210                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
4211                 ;;
4212         (w*)
4213                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
4214                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
4215                 ;;
4216         esac
4217 fi
4218
4219 for cf_dir in $SRC_SUBDIRS
4220 do
4221         if test ! -d $srcdir/$cf_dir ; then
4222                 continue
4223         elif test -f $srcdir/$cf_dir/modules; then
4224
4225                 SHARED_LIB=
4226                 Libs_To_Make=
4227                 cf_awk_program=
4228                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
4229                 then
4230                         cf_awk_program="$cf_awk_program\
4231 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
4232 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
4233 "
4234                 fi
4235
4236                 if test "x$WILDCARD_SYMS" = xno
4237                 then
4238                         cf_awk_program="$cf_awk_program\
4239 /[[     ]]_\\*;/ { skip=1; next; }\
4240 "
4241                 fi
4242
4243                 if test "x$cf_awk_program" != "x"
4244                 then
4245                         cat >>$cf_dir/Makefile <<CF_EOF
4246
4247 # Generated by CF_LIB_RULES
4248 resulting.map: $UNALTERED_SYMS
4249         $AWK 'BEGIN { skip = 1; last=""; } \
4250 $cf_awk_program \
4251 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
4252  skip = 0; last = \[$]\[$]0; } \
4253 END { print last; }' < $UNALTERED_SYMS >\[$]@
4254
4255 distclean::
4256         rm -f resulting.map
4257 CF_EOF
4258                 fi
4259
4260                 for cf_item in $cf_LIST_MODELS
4261                 do
4262                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4263                         if test "$cf_dir" = "c++"
4264                         then
4265                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4266                         else
4267                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4268                         fi
4269                         test -z "$cf_libname" && cf_libname="$cf_dir"
4270                         if test $cf_item = shared ; then
4271                                 if test -n "${LIB_SUFFIX}"
4272                                 then
4273                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4274                                 else
4275                                         cf_shared_suffix="$cf_suffix"
4276                                 fi
4277                                 if test "$cf_cv_do_symlinks" = yes ; then
4278                                         cf_version_name=
4279
4280                                         case "$cf_cv_shlib_version" in
4281                                         (rel)
4282                                                 cf_version_name=REL_VERSION
4283                                                 ;;
4284                                         (abi)
4285                                                 cf_version_name=ABI_VERSION
4286                                                 ;;
4287                                         esac
4288
4289                                         if test -n "$cf_version_name"
4290                                         then
4291                                                 case "$cf_cv_system_name" in
4292                                                 (darwin*)
4293                                                         # "w", etc?
4294                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
4295                                                         ;;
4296                                                 (*)
4297                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
4298                                                         ;;
4299                                                 esac
4300                                         fi
4301                                         if test -n "${USE_LIB_SUFFIX}"
4302                                         then
4303                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4304                                         else
4305                                                 cf_shared_suffix="$cf_suffix"
4306                                         fi
4307                                 fi
4308                                 # cygwin needs import library, and has unique naming convention
4309                                 # use autodetected ${cf_prefix} for import lib and static lib, but
4310                                 # use 'cyg' prefix for shared lib.
4311                                 case $cf_cv_shlib_version in
4312                                 (cygdll)
4313                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4314                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
4315                                         ;;
4316                                 (msysdll)
4317                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4318                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
4319                                         ;;
4320                                 (mingw)
4321                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4322                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
4323                                         ;;
4324                                 (msvcdll)
4325                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4326                                         cf_add_lib="../lib/${cf_libname}${cf_cygsuf}"
4327                                         ;;
4328                                 (*)
4329                                         cf_add_lib=
4330                                         ;;
4331                                 esac
4332                                 if test -n "$cf_add_lib"
4333                                 then
4334                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4335                                         continue
4336                                 fi
4337                         fi
4338                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
4339                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4340                 done
4341
4342                 if test $cf_dir = ncurses ; then
4343                         cf_subsets="$LIB_SUBSETS"
4344                         cf_r_parts="$cf_subsets"
4345                         cf_liblist="$Libs_To_Make"
4346
4347                         while test -n "$cf_r_parts"
4348                         do
4349                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
4350                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
4351                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
4352                                         cf_add_lib=
4353                                         case $cf_l_parts in
4354                                         (*termlib*)
4355                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
4356                                                 ;;
4357                                         (*ticlib*)
4358                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
4359                                                 ;;
4360                                         (*)
4361                                                 break
4362                                                 ;;
4363                                         esac
4364                                         if test -n "$cf_add_lib"; then
4365                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
4366                                         fi
4367                                 else
4368                                         break
4369                                 fi
4370                         done
4371                 else
4372                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
4373                 fi
4374
4375                 if test $cf_dir = c++; then
4376                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
4377                                 cf_list=
4378                                 for cf_item in $Libs_To_Make
4379                                 do
4380                                         case $cf_item in
4381                                         (*.a)
4382                                                 ;;
4383                                         (*)
4384                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
4385                                                 ;;
4386                                         esac
4387                                         for cf_test in $cf_list
4388                                         do
4389                                                 if test "$cf_test" = "$cf_item"
4390                                                 then
4391                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
4392                                                         cf_item=
4393                                                         break
4394                                                 fi
4395                                         done
4396                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
4397                                 done
4398                                 Libs_To_Make="$cf_list"
4399                         fi
4400                 fi
4401
4402                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
4403                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
4404                         $cf_dir/Makefile >$cf_dir/Makefile.out
4405                 mv $cf_dir/Makefile.out $cf_dir/Makefile
4406
4407                 $AWK -f $srcdir/mk-0th.awk \
4408                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
4409                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4410
4411                 for cf_subset in $cf_subsets
4412                 do
4413                         cf_subdirs=
4414                         for cf_item in $cf_LIST_MODELS
4415                         do
4416
4417                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
4418                         CF_UPPER(cf_ITEM,$cf_item)
4419
4420                         CXX_MODEL=$cf_ITEM
4421                         if test "$CXX_MODEL" = SHARED; then
4422                                 case $cf_cv_shlib_version in
4423                                 (cygdll|msysdll|mingw|msvcdll)
4424                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
4425                                         with_shared_cxx=yes
4426                                         ;;
4427                                 (*)
4428                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
4429                                         ;;
4430                                 esac
4431                         fi
4432
4433                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4434                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
4435
4436                         # Test for case where we build libtinfo with a different name.
4437                         cf_libname=$cf_dir
4438                         if test $cf_dir = ncurses ; then
4439                                 case $cf_subset in
4440                                 (*base*)
4441                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
4442                                         ;;
4443                                 (*termlib*)
4444                                         cf_libname=$TINFO_LIB_SUFFIX
4445                                         ;;
4446                                 (ticlib*)
4447                                         cf_libname=$TICS_LIB_SUFFIX
4448                                         ;;
4449                                 esac
4450                         elif test $cf_dir = c++ ; then
4451                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4452                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4453                         else
4454                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4455                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4456                         fi
4457                         if test -n "${USE_ARG_SUFFIX}" ; then
4458                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
4459                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${USE_LIB_SUFFIX}%%"`
4460                         fi
4461
4462                         # These dependencies really are for development, not
4463                         # builds, but they are useful in porting, too.
4464                         cf_depend="../include/ncurses_cfg.h"
4465                         if test "$srcdir" = "."; then
4466                                 cf_reldir="."
4467                         else
4468                                 cf_reldir="\${srcdir}"
4469                         fi
4470
4471                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
4472                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
4473                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
4474                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
4475                         fi
4476
4477                         cf_dir_suffix=
4478                         old_cf_suffix="$cf_suffix"
4479                         if test "$cf_cv_shlib_version_infix" = yes ; then
4480                         if test -n "$USE_LIB_SUFFIX" ; then
4481                                 case $USE_LIB_SUFFIX in
4482                                 (tw*)
4483                                         cf_libname=`echo $cf_libname | sed 's/tw'$EXTRA_SUFFIX'$//'`
4484                                         cf_suffix=`echo $cf_suffix | sed 's/^tw'$EXTRA_SUFFIX'//'`
4485                                         cf_dir_suffix=tw$EXTRA_SUFFIX
4486                                         ;;
4487                                 (t*)
4488                                         cf_libname=`echo $cf_libname | sed 's/t'$EXTRA_SUFFIX'$//'`
4489                                         cf_suffix=`echo $cf_suffix | sed 's/^t'$EXTRA_SUFFIX'//'`
4490                                         cf_dir_suffix=t$EXTRA_SUFFIX
4491                                         ;;
4492                                 (w*)
4493                                         cf_libname=`echo $cf_libname | sed 's/w'$EXTRA_SUFFIX'$//'`
4494                                         cf_suffix=`echo $cf_suffix | sed 's/^w'$EXTRA_SUFFIX'//'`
4495                                         cf_dir_suffix=w$EXTRA_SUFFIX
4496                                         ;;
4497                                 (*)
4498                                         cf_libname=`echo $cf_libname | sed 's/'$EXTRA_SUFFIX'$//'`
4499                                         cf_suffix=`echo $cf_suffix | sed 's/^'$EXTRA_SUFFIX'//'`
4500                                         cf_dir_suffix=$EXTRA_SUFFIX
4501                                         ;;
4502                                 esac
4503                         fi
4504                         fi
4505
4506                         $AWK -f $srcdir/mk-1st.awk \
4507                                 name=${cf_libname}${cf_dir_suffix} \
4508                                 traces=$LIB_TRACING \
4509                                 MODEL=$cf_ITEM \
4510                                 CXX_MODEL=$CXX_MODEL \
4511                                 model=$cf_subdir \
4512                                 prefix=$cf_prefix \
4513                                 suffix=$cf_suffix \
4514                                 subset=$cf_subset \
4515                                 driver=$cf_cv_term_driver \
4516                                 SymLink="$LN_S" \
4517                                 TermlibRoot=$TINFO_NAME \
4518                                 TermlibSuffix=$TINFO_SUFFIX \
4519                                 ShlibVer=$cf_cv_shlib_version \
4520                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
4521                                 ReLink=${cf_cv_do_relink:-no} \
4522                                 ReRanlib=${cf_cv_do_reranlib:-yes} \
4523                                 DoLinks=$cf_cv_do_symlinks \
4524                                 rmSoLocs=$cf_cv_rm_so_locs \
4525                                 ldconfig="$LDCONFIG" \
4526                                 overwrite=$WITH_OVERWRITE \
4527                                 depend="$cf_depend" \
4528                                 host="$host" \
4529                                 libtool_version="$LIBTOOL_VERSION" \
4530                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4531
4532                         cf_suffix="$old_cf_suffix"
4533
4534                         for cf_subdir2 in $cf_subdirs lib
4535                         do
4536                                 test $cf_subdir = $cf_subdir2 && break
4537                         done
4538                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
4539                         $AWK -f $srcdir/mk-2nd.awk \
4540                                 name=$cf_dir \
4541                                 traces=$LIB_TRACING \
4542                                 MODEL=$cf_ITEM \
4543                                 model=$cf_subdir \
4544                                 subset=$cf_subset \
4545                                 srcdir=$srcdir \
4546                                 echo=$WITH_ECHO \
4547                                 crenames=$cf_cv_prog_CC_c_o \
4548                                 cxxrenames=$cf_cv_prog_CXX_c_o \
4549                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4550                         cf_subdirs="$cf_subdirs $cf_subdir"
4551                         done
4552                 done
4553         fi
4554
4555         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
4556 done
4557
4558 for cf_dir in $SRC_SUBDIRS
4559 do
4560         if test ! -d $srcdir/$cf_dir ; then
4561                 continue
4562         fi
4563
4564         if test -f $cf_dir/Makefile ; then
4565                 case "$cf_dir" in
4566                 (Ada95)
4567                         echo 'libs \' >> Makefile
4568                         echo 'install.libs \' >> Makefile
4569                         echo 'uninstall.libs ::' >> Makefile
4570                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
4571                         ;;
4572                 esac
4573         fi
4574
4575         if test -f $srcdir/$cf_dir/modules; then
4576                 echo >> Makefile
4577                 if test -f $srcdir/$cf_dir/headers; then
4578 cat >> Makefile <<CF_EOF
4579 install.includes \\
4580 uninstall.includes \\
4581 CF_EOF
4582                 fi
4583 if test "$cf_dir" != "c++" ; then
4584 echo 'lint \' >> Makefile
4585 fi
4586 cat >> Makefile <<CF_EOF
4587 libs \\
4588 lintlib \\
4589 install.libs \\
4590 uninstall.libs \\
4591 install.$cf_dir \\
4592 uninstall.$cf_dir ::
4593         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
4594 CF_EOF
4595         elif test -f $srcdir/$cf_dir/headers; then
4596 cat >> Makefile <<CF_EOF
4597
4598 libs \\
4599 install.libs \\
4600 uninstall.libs \\
4601 install.includes \\
4602 uninstall.includes ::
4603         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
4604 CF_EOF
4605 fi
4606 done
4607
4608 if test "x$cf_with_db_install" = xyes; then
4609 cat >> Makefile <<CF_EOF
4610
4611 install.libs uninstall.libs \\
4612 install.data uninstall.data ::
4613 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
4614 CF_EOF
4615 else
4616 cat >> Makefile <<CF_EOF
4617
4618 install.libs uninstall.libs ::
4619         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
4620 CF_EOF
4621 fi
4622
4623 if test "x$cf_with_manpages" = xyes; then
4624 cat >> Makefile <<CF_EOF
4625
4626 install.man \\
4627 uninstall.man ::
4628         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
4629 CF_EOF
4630 fi
4631
4632 cat >> Makefile <<CF_EOF
4633
4634 distclean ::
4635         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
4636         rm -f headers.sh headers.sed mk_shared_lib.sh
4637         rm -f edit_man.* man_alias.*
4638         rm -rf \${DIRS_TO_MAKE}
4639 CF_EOF
4640
4641 # Special case: tack's manpage lives in its own directory.
4642 if test "x$cf_with_manpages" = xyes; then
4643 if test "x$cf_with_tack" = "xyes"; then
4644 cat >> Makefile <<CF_EOF
4645
4646 install.man \\
4647 uninstall.man ::
4648         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
4649 CF_EOF
4650 fi
4651 fi
4652
4653 dnl If we're installing into a subdirectory of /usr/include, etc., we should
4654 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
4655 dnl anything, and will make it more standardized.  It's awkward to decide this
4656 dnl at configuration because of quoting, so we'll simply make all headers
4657 dnl installed via a script that can do the right thing.
4658
4659 rm -f headers.sed headers.sh
4660
4661 dnl ( generating this script makes the makefiles a little tidier :-)
4662 echo creating headers.sh
4663 cat >headers.sh <<CF_EOF
4664 #! $SHELL
4665 # This shell script is generated by the 'configure' script.  It is invoked in a
4666 # subdirectory of the build tree.  It generates a sed-script in the parent
4667 # directory that is used to adjust includes for header files that reside in a
4668 # subdirectory of /usr/include, etc.
4669 PRG=""
4670 while test \[$]# != 3
4671 do
4672 PRG="\$PRG \[$]1"; shift
4673 done
4674 DST=\[$]1
4675 REF=\[$]2
4676 SRC=\[$]3
4677 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
4678 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
4679 echo installing \$SRC in \$DST
4680 CF_EOF
4681
4682 if test $WITH_CURSES_H = yes; then
4683         cat >>headers.sh <<CF_EOF
4684 case \$DST in
4685 (/*/include/*)
4686         END=\`basename \$DST\`
4687         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
4688         do
4689                 NAME=\`basename \$i\`
4690                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4691         done
4692         ;;
4693 (*)
4694         echo "" >> \$TMPSED
4695         ;;
4696 esac
4697 CF_EOF
4698
4699 else
4700         cat >>headers.sh <<CF_EOF
4701 case \$DST in
4702 (/*/include/*)
4703         END=\`basename \$DST\`
4704         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
4705         do
4706                 NAME=\`basename \$i\`
4707                 if test "\$NAME" = "curses.h"
4708                 then
4709                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4710                         NAME=ncurses.h
4711                 fi
4712                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4713         done
4714         ;;
4715 (*)
4716         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4717         ;;
4718 esac
4719 CF_EOF
4720 fi
4721 cat >>headers.sh <<CF_EOF
4722 rm -f \$TMPSRC
4723 sed -f \$TMPSED \$SRC > \$TMPSRC
4724 NAME=\`basename \$SRC\`
4725 CF_EOF
4726 if test $WITH_CURSES_H != yes; then
4727         cat >>headers.sh <<CF_EOF
4728 test "\$NAME" = "curses.h" && NAME=ncurses.h
4729 CF_EOF
4730 fi
4731 cat >>headers.sh <<CF_EOF
4732 # Just in case someone gzip'd manpages, remove the conflicting copy.
4733 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
4734
4735 eval \$PRG \$TMPSRC \$DST/\$NAME
4736 rm -f \$TMPSRC \$TMPSED
4737 CF_EOF
4738
4739 chmod 0755 headers.sh
4740
4741 for cf_dir in $SRC_SUBDIRS
4742 do
4743         if test ! -d $srcdir/$cf_dir ; then
4744                 continue
4745         fi
4746
4747         if test -f $srcdir/$cf_dir/headers; then
4748                 $AWK -f $srcdir/mk-hdr.awk \
4749                         subset="$LIB_SUBSETS" \
4750                         compat="$WITH_CURSES_H" \
4751                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
4752         fi
4753
4754         if test -f $srcdir/$cf_dir/modules; then
4755                 if test "$cf_dir" != "c++" ; then
4756                         cat >>$cf_dir/Makefile <<"CF_EOF"
4757 depend : ${AUTO_SRC}
4758         makedepend -- ${CPPFLAGS} -- ${C_SRC}
4759
4760 # DO NOT DELETE THIS LINE -- make depend depends on it.
4761 CF_EOF
4762                 fi
4763         fi
4764 done
4765 AC_SUBST(Libs_To_Make)
4766 ])dnl
4767 dnl ---------------------------------------------------------------------------
4768 dnl CF_LIB_SONAME version: 6 updated: 2017/01/21 11:06:25
4769 dnl -------------
4770 dnl Find the and soname for the given shared library.  Set the cache variable
4771 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
4772 dnl variable to "unknown".
4773 dnl
4774 dnl $1 = headers
4775 dnl $2 = code
4776 dnl $3 = library name
4777 AC_DEFUN([CF_LIB_SONAME],
4778 [
4779 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
4780
4781 cf_cv_$3_soname=unknown
4782 if test "$cross_compiling" != yes ; then
4783 cat >conftest.$ac_ext <<CF_EOF
4784 $1
4785 int main(void)
4786 {
4787 $2
4788         ${cf_cv_main_return:-return}(0);
4789 }
4790 CF_EOF
4791 cf_save_LIBS="$LIBS"
4792         CF_ADD_LIB($3)
4793         if AC_TRY_EVAL(ac_compile) ; then
4794                 if AC_TRY_EVAL(ac_link) ; then
4795                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
4796                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
4797                 fi
4798         fi
4799 rm -rf conftest*
4800 LIBS="$cf_save_LIBS"
4801 fi
4802 ])
4803 ])
4804 dnl ---------------------------------------------------------------------------
4805 dnl CF_LIB_SUFFIX version: 26 updated: 2020/04/04 10:11:47
4806 dnl -------------
4807 dnl Compute the library file-suffix from the given model name
4808 dnl $1 = model name
4809 dnl $2 = variable to set (the nominal library suffix)
4810 dnl $3 = dependency variable to set (actual filename)
4811 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4812 AC_DEFUN([CF_LIB_SUFFIX],
4813 [
4814         case X$1 in
4815         (Xlibtool)
4816                 $2='.la'
4817                 $3=[$]$2
4818                 ;;
4819         (Xdebug)
4820                 case $cf_cv_system_name in
4821                 (*-msvc*)
4822                         $2='_g.lib'
4823                         ;;
4824                 (*)
4825                         $2='_g.a'
4826                         ;;
4827                 esac
4828                 $3=[$]$2
4829                 ;;
4830         (Xprofile)
4831                 case $cf_cv_system_name in
4832                 (*-msvc*)
4833                         $2='_p.lib'
4834                         ;;
4835                 (*)
4836                         $2='_p.a'
4837                         ;;
4838                 esac
4839                 $3=[$]$2
4840                 ;;
4841         (Xshared)
4842                 case $cf_cv_system_name in
4843                 (aix[[5-7]]*)
4844                         $2='.so'
4845                         $3=[$]$2
4846                         ;;
4847                 (*-msvc*)
4848                         $2='.dll'
4849                         $3='.dll.lib'
4850                         ;;
4851                 (cygwin*|msys*|mingw*)
4852                         $2='.dll'
4853                         $3='.dll.a'
4854                         ;;
4855                 (darwin*)
4856                         $2='.dylib'
4857                         $3=[$]$2
4858                         ;;
4859                 (hpux*)
4860                         case $target in
4861                         (ia64*)
4862                                 $2='.so'
4863                                 $3=[$]$2
4864                                 ;;
4865                         (*)
4866                                 $2='.sl'
4867                                 $3=[$]$2
4868                                 ;;
4869                         esac
4870                         ;;
4871                 (*)
4872                         $2='.so'
4873                         $3=[$]$2
4874                         ;;
4875                 esac
4876                 ;;
4877         (*)
4878                 case $target in
4879                 (*-msvc*)
4880                         $2='.lib'
4881                         ;;
4882                 (*)
4883                         $2='.a'
4884                         ;;
4885                 esac
4886                 $3=[$]$2
4887                 ;;
4888         esac
4889         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
4890         then
4891                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
4892                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
4893         fi
4894 ])dnl
4895 dnl ---------------------------------------------------------------------------
4896 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
4897 dnl -----------
4898 dnl Compute the string to append to -library from the given model name
4899 dnl $1 = model name
4900 dnl $2 = variable to set
4901 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4902 AC_DEFUN([CF_LIB_TYPE],
4903 [
4904         case $1 in
4905         (libtool) $2=''   ;;
4906         (normal)  $2=''   ;;
4907         (debug)   $2='_g' ;;
4908         (profile) $2='_p' ;;
4909         (shared)  $2=''   ;;
4910         esac
4911         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
4912 ])dnl
4913 dnl ---------------------------------------------------------------------------
4914 dnl CF_LINK_DATAONLY version: 13 updated: 2020/02/08 15:59:30
4915 dnl ----------------
4916 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
4917 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
4918 dnl have to provide wrappers for global tables to ensure they're linked
4919 dnl properly.
4920 AC_DEFUN([CF_LINK_DATAONLY],
4921 [
4922 AC_MSG_CHECKING([if data-only library module links])
4923 AC_CACHE_VAL(cf_cv_link_dataonly,[
4924         rm -f conftest.a
4925         cat >conftest.$ac_ext <<EOF
4926 #line __oline__ "configure"
4927 int     testdata[[3]] = { 123, 456, 789 };
4928 EOF
4929         if AC_TRY_EVAL(ac_compile) ; then
4930                 mv conftest.o data.o && \
4931                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
4932         fi
4933         rm -f conftest.$ac_ext data.o
4934         cat >conftest.$ac_ext <<EOF
4935 #line __oline__ "configure"
4936 int     testfunc(void)
4937 {
4938 #if defined(NeXT)
4939         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
4940 #else
4941         extern int testdata[[3]];
4942         return testdata[[0]] == 123
4943            &&  testdata[[1]] == 456
4944            &&  testdata[[2]] == 789;
4945 #endif
4946 }
4947 EOF
4948         if AC_TRY_EVAL(ac_compile); then
4949                 mv conftest.o func.o && \
4950                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
4951         fi
4952         rm -f conftest.$ac_ext func.o
4953         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
4954         cf_saveLIBS="$LIBS"
4955         LIBS="conftest.a $LIBS"
4956         AC_TRY_RUN([
4957         int main(void)
4958         {
4959                 extern int testfunc();
4960                 ${cf_cv_main_return:-return} (!testfunc());
4961         }
4962         ],
4963         [cf_cv_link_dataonly=yes],
4964         [cf_cv_link_dataonly=no],
4965         [cf_cv_link_dataonly=unknown])
4966         LIBS="$cf_saveLIBS"
4967         ])
4968 AC_MSG_RESULT($cf_cv_link_dataonly)
4969
4970 if test "$cf_cv_link_dataonly" = no ; then
4971         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
4972         BROKEN_LINKER=1
4973 fi
4974 AC_SUBST(BROKEN_LINKER)
4975
4976 ])dnl
4977 dnl ---------------------------------------------------------------------------
4978 dnl CF_LINK_FUNCS version: 9 updated: 2017/01/21 11:11:02
4979 dnl -------------
4980 dnl Most Unix systems have both link and symlink, a few don't have symlink.
4981 dnl A few non-Unix systems implement symlink, but not link.
4982 dnl A few non-systems implement neither (or have nonfunctional versions).
4983 AC_DEFUN([CF_LINK_FUNCS],
4984 [
4985 AC_CHECK_HEADERS( \
4986 unistd.h \
4987 )
4988 AC_CHECK_FUNCS( \
4989         remove \
4990         unlink )
4991
4992 if test "$cross_compiling" = yes ; then
4993         AC_CHECK_FUNCS( \
4994                 link \
4995                 symlink )
4996 else
4997         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
4998                 cf_cv_link_funcs=
4999                 for cf_func in link symlink ; do
5000                         AC_TRY_RUN([
5001 #include <sys/types.h>
5002 #include <sys/stat.h>
5003 #ifdef HAVE_UNISTD_H
5004 #include <unistd.h>
5005 #endif
5006 int main(void)
5007 {
5008         int fail = 0;
5009         char *src = "config.log";
5010         char *dst = "conftest.chk";
5011         struct stat src_sb;
5012         struct stat dst_sb;
5013
5014         stat(src, &src_sb);
5015         fail = ($cf_func("config.log", "conftest.chk") < 0)
5016             || (stat(dst, &dst_sb) < 0)
5017             || (dst_sb.st_mtime != src_sb.st_mtime);
5018 #ifdef HAVE_UNLINK
5019         unlink(dst);
5020 #else
5021         remove(dst);
5022 #endif
5023         ${cf_cv_main_return:-return} (fail);
5024 }
5025                         ],[
5026                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
5027                         eval 'ac_cv_func_'$cf_func'=yes'],[
5028                         eval 'ac_cv_func_'$cf_func'=no'],[
5029                         eval 'ac_cv_func_'$cf_func'=error'])
5030                 done
5031                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
5032         ])
5033         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
5034         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
5035 fi
5036 ])dnl
5037 dnl ---------------------------------------------------------------------------
5038 dnl CF_MAKEFLAGS version: 18 updated: 2018/02/21 21:26:03
5039 dnl ------------
5040 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
5041 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
5042 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
5043 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
5044 AC_DEFUN([CF_MAKEFLAGS],
5045 [
5046 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
5047         cf_cv_makeflags=''
5048         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
5049         do
5050                 cat >cf_makeflags.tmp <<CF_EOF
5051 SHELL = $SHELL
5052 all :
5053         @ echo '.$cf_option'
5054 CF_EOF
5055                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
5056                 case "$cf_result" in
5057                 (.*k|.*kw)
5058                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
5059                         case "$cf_result" in
5060                         (.*CC=*)        cf_cv_makeflags=
5061                                 ;;
5062                         (*)     cf_cv_makeflags=$cf_option
5063                                 ;;
5064                         esac
5065                         break
5066                         ;;
5067                 (.-)
5068                         ;;
5069                 (*)
5070                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
5071                         ;;
5072                 esac
5073         done
5074         rm -f cf_makeflags.tmp
5075 ])
5076
5077 AC_SUBST(cf_cv_makeflags)
5078 ])dnl
5079 dnl ---------------------------------------------------------------------------
5080 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
5081 dnl ------------
5082 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
5083 dnl a monocase filesystem.
5084 AC_DEFUN([CF_MAKE_TAGS],[
5085 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
5086
5087 AC_CHECK_PROGS(CTAGS, exctags ctags)
5088 AC_CHECK_PROGS(ETAGS, exetags etags)
5089
5090 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
5091
5092 if test "$cf_cv_mixedcase" = yes ; then
5093         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
5094 else
5095         MAKE_UPPER_TAGS=no
5096 fi
5097
5098 if test "$MAKE_UPPER_TAGS" = yes ; then
5099         MAKE_UPPER_TAGS=
5100 else
5101         MAKE_UPPER_TAGS="#"
5102 fi
5103
5104 if test "$MAKE_LOWER_TAGS" = yes ; then
5105         MAKE_LOWER_TAGS=
5106 else
5107         MAKE_LOWER_TAGS="#"
5108 fi
5109
5110 AC_SUBST(CTAGS)
5111 AC_SUBST(ETAGS)
5112
5113 AC_SUBST(MAKE_UPPER_TAGS)
5114 AC_SUBST(MAKE_LOWER_TAGS)
5115 ])dnl
5116 dnl ---------------------------------------------------------------------------
5117 dnl CF_MANPAGE_FORMAT version: 11 updated: 2015/04/18 08:56:57
5118 dnl -----------------
5119 dnl Option to allow user to override automatic configuration of manpage format.
5120 dnl There are several special cases:
5121 dnl
5122 dnl     gzip - man checks for, can display gzip'd files
5123 dnl     compress - man checks for, can display compressed files
5124 dnl     BSDI - files in the cat-directories are suffixed ".0"
5125 dnl     formatted - installer should format (put files in cat-directory)
5126 dnl     catonly - installer should only format, e.g., for a turnkey system.
5127 dnl
5128 dnl There are other configurations which this macro does not test, e.g., HPUX's
5129 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
5130 dnl convention would not match our use).
5131 AC_DEFUN([CF_MANPAGE_FORMAT],
5132 [
5133 AC_REQUIRE([CF_PATHSEP])
5134 AC_MSG_CHECKING(format of man-pages)
5135
5136 AC_ARG_WITH(manpage-format,
5137         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
5138                           optionally formatted/catonly, e.g., gzip,formatted],
5139         [MANPAGE_FORMAT=$withval],
5140         [MANPAGE_FORMAT=unknown])
5141
5142 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
5143 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
5144
5145 cf_unknown=
5146
5147 case $MANPAGE_FORMAT in
5148 (unknown)
5149         if test -z "$MANPATH" ; then
5150                 MANPATH="/usr/man:/usr/share/man"
5151         fi
5152
5153         # look for the 'date' man-page (it's most likely to be installed!)
5154         MANPAGE_FORMAT=
5155         cf_preform=no
5156         cf_catonly=yes
5157         cf_example=date
5158
5159         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
5160         for cf_dir in $MANPATH; do
5161                 test -z "$cf_dir" && cf_dir=/usr/man
5162                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
5163                 do
5164                         cf_test=`echo $cf_name | sed -e 's/*//'`
5165                         if test "x$cf_test" = "x$cf_name" ; then
5166
5167                                 case "$cf_name" in
5168                                 (*.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
5169                                 (*.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
5170                                 (*.0)  MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
5171                                 (*)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
5172                                 esac
5173
5174                                 case "$cf_name" in
5175                                 ($cf_dir/man*)
5176                                         cf_catonly=no
5177                                         ;;
5178                                 ($cf_dir/cat*)
5179                                         cf_preform=yes
5180                                         ;;
5181                                 esac
5182                                 break
5183                         fi
5184
5185                         # if we found a match in either man* or cat*, stop looking
5186                         if test -n "$MANPAGE_FORMAT" ; then
5187                                 cf_found=no
5188                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
5189                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
5190                                 case "$cf_name" in
5191                                 ($cf_dir/cat*)
5192                                         cf_found=yes
5193                                         ;;
5194                                 esac
5195                                 test $cf_found=yes && break
5196                         fi
5197                 done
5198                 # only check the first directory in $MANPATH where we find manpages
5199                 if test -n "$MANPAGE_FORMAT" ; then
5200                         break
5201                 fi
5202         done
5203         # if we did not find the example, just assume it is normal
5204         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
5205         IFS="$ac_save_ifs"
5206         ;;
5207 (*)
5208         for cf_option in $MANPAGE_FORMAT; do
5209         case $cf_option in
5210         (gzip|compress|BSDI|normal|formatted|catonly)
5211                 ;;
5212         (*)
5213                 cf_unknown="$cf_unknown $cf_option"
5214                 ;;
5215         esac
5216         done
5217         ;;
5218 esac
5219
5220 AC_MSG_RESULT($MANPAGE_FORMAT)
5221 if test -n "$cf_unknown" ; then
5222         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
5223 fi
5224 ])dnl
5225 dnl ---------------------------------------------------------------------------
5226 dnl CF_MANPAGE_RENAMES version: 10 updated: 2015/08/05 20:44:28
5227 dnl ------------------
5228 dnl The Debian people have their own naming convention for manpages.  This
5229 dnl option lets us override the name of the file containing renaming, or
5230 dnl disable it altogether.
5231 AC_DEFUN([CF_MANPAGE_RENAMES],
5232 [
5233 AC_MSG_CHECKING(for manpage renaming)
5234
5235 AC_ARG_WITH(manpage-renames,
5236         [  --with-manpage-renames  specify manpage-renaming],
5237         [MANPAGE_RENAMES=$withval],
5238         [MANPAGE_RENAMES=yes])
5239
5240 case ".$MANPAGE_RENAMES" in
5241 (.no)
5242         ;;
5243 (.|.yes)
5244         # Debian 'man' program?
5245         if test -f /etc/debian_version ; then
5246                 MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
5247         else
5248                 MANPAGE_RENAMES=no
5249         fi
5250         ;;
5251 esac
5252
5253 if test "$MANPAGE_RENAMES" != no ; then
5254         if test -f $srcdir/man/$MANPAGE_RENAMES ; then
5255                 MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
5256         elif test ! -f $MANPAGE_RENAMES ; then
5257                 AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
5258         fi
5259
5260         test ! -d man && mkdir man
5261
5262         # Construct a sed-script to perform renaming within man-pages
5263         if test -n "$MANPAGE_RENAMES" ; then
5264                 test ! -d man && mkdir man
5265                 $SHELL $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
5266         fi
5267 fi
5268
5269 AC_MSG_RESULT($MANPAGE_RENAMES)
5270 AC_SUBST(MANPAGE_RENAMES)
5271 ])dnl
5272 dnl ---------------------------------------------------------------------------
5273 dnl CF_MANPAGE_SYMLINKS version: 6 updated: 2015/04/17 21:13:04
5274 dnl -------------------
5275 dnl Some people expect each tool to make all aliases for manpages in the
5276 dnl man-directory.  This accommodates the older, less-capable implementations
5277 dnl of 'man', and is optional.
5278 AC_DEFUN([CF_MANPAGE_SYMLINKS],
5279 [
5280 AC_MSG_CHECKING(if manpage aliases will be installed)
5281
5282 AC_ARG_WITH(manpage-aliases,
5283         [  --with-manpage-aliases  specify manpage-aliases using .so],
5284         [MANPAGE_ALIASES=$withval],
5285         [MANPAGE_ALIASES=yes])
5286
5287 AC_MSG_RESULT($MANPAGE_ALIASES)
5288
5289 case "x$LN_S" in
5290 (xln*)
5291         cf_use_symlinks=yes
5292         ;;
5293 (*)
5294         cf_use_symlinks=no
5295         ;;
5296 esac
5297
5298 MANPAGE_SYMLINKS=no
5299 if test "$MANPAGE_ALIASES" = yes ; then
5300 AC_MSG_CHECKING(if manpage symlinks should be used)
5301
5302 AC_ARG_WITH(manpage-symlinks,
5303         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
5304         [MANPAGE_SYMLINKS=$withval],
5305         [MANPAGE_SYMLINKS=$cf_use_symlinks])
5306
5307 if test "$$cf_use_symlinks" = no; then
5308 if test "$MANPAGE_SYMLINKS" = yes ; then
5309         AC_MSG_WARN(cannot make symlinks, will use .so files)
5310         MANPAGE_SYMLINKS=no
5311 fi
5312 fi
5313
5314 AC_MSG_RESULT($MANPAGE_SYMLINKS)
5315 fi
5316
5317 ])dnl
5318 dnl ---------------------------------------------------------------------------
5319 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
5320 dnl --------------
5321 dnl This option causes manpages to be run through tbl(1) to generate tables
5322 dnl correctly.
5323 AC_DEFUN([CF_MANPAGE_TBL],
5324 [
5325 AC_MSG_CHECKING(for manpage tbl)
5326
5327 AC_ARG_WITH(manpage-tbl,
5328         [  --with-manpage-tbl      specify manpage processing with tbl],
5329         [MANPAGE_TBL=$withval],
5330         [MANPAGE_TBL=no])
5331
5332 AC_MSG_RESULT($MANPAGE_TBL)
5333 ])dnl
5334 dnl ---------------------------------------------------------------------------
5335 dnl CF_MAN_PAGES version: 47 updated: 2017/08/12 07:58:51
5336 dnl ------------
5337 dnl Try to determine if the man-pages on the system are compressed, and if
5338 dnl so, what format is used.  Use this information to construct a script that
5339 dnl will install man-pages.
5340 AC_DEFUN([CF_MAN_PAGES],
5341 [
5342 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
5343 CF_MANPAGE_FORMAT
5344 CF_MANPAGE_RENAMES
5345 CF_MANPAGE_SYMLINKS
5346 CF_MANPAGE_TBL
5347
5348 if test "$prefix" = "NONE" ; then
5349         cf_prefix="$ac_default_prefix"
5350 else
5351         cf_prefix="$prefix"
5352 fi
5353
5354 case "$MANPAGE_FORMAT" in
5355 (*catonly*)
5356         cf_format=yes
5357         cf_inboth=no
5358         ;;
5359 (*formatted*)
5360         cf_format=yes
5361         cf_inboth=yes
5362         ;;
5363 (*)
5364         cf_format=no
5365         cf_inboth=no
5366         ;;
5367 esac
5368
5369 test ! -d man && mkdir man
5370
5371 cf_so_strip=
5372 cf_compress=
5373 case "$MANPAGE_FORMAT" in
5374 (*compress*)
5375         cf_so_strip="Z"
5376         cf_compress=compress
5377         ;;
5378 (*gzip*)
5379         cf_so_strip="gz"
5380         cf_compress=gzip
5381         ;;
5382 esac
5383
5384 cf_edit_man=./edit_man.sh
5385 cf_man_alias=`pwd`/man_alias.sed
5386
5387 cat >$cf_edit_man <<CF_EOF
5388 #! $SHELL
5389 # this script is generated by the configure-script CF_MAN_PAGES macro.
5390
5391 prefix="$cf_prefix"
5392 datarootdir="$datarootdir"
5393 datadir="$datadir"
5394
5395 NCURSES_MAJOR="$NCURSES_MAJOR"
5396 NCURSES_MINOR="$NCURSES_MINOR"
5397 NCURSES_PATCH="$NCURSES_PATCH"
5398
5399 NCURSES_OSPEED="$NCURSES_OSPEED"
5400 TERMINFO="$TERMINFO"
5401
5402 INSTALL="$INSTALL"
5403 INSTALL_DATA="$INSTALL_DATA"
5404
5405 transform="$program_transform_name"
5406
5407 TMP=\${TMPDIR:=/tmp}/man\$\$
5408 trap "rm -f \$TMP" 0 1 2 3 15
5409
5410 form=\[$]1
5411 shift || exit 1
5412
5413 verb=\[$]1
5414 shift || exit 1
5415
5416 mandir=\[$]1
5417 shift || exit 1
5418
5419 srcdir=\[$]1
5420 top_srcdir=\[$]srcdir/..
5421 shift || exit 1
5422
5423 if test "\$form" = normal ; then
5424         if test "$cf_format" = yes ; then
5425         if test "$cf_inboth" = no ; then
5426                 $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
5427                 exit $?
5428         fi
5429         fi
5430         cf_subdir=\$mandir/man
5431         cf_tables=$MANPAGE_TBL
5432 else
5433         cf_subdir=\$mandir/cat
5434         cf_tables=yes
5435 fi
5436
5437 # process the list of source-files
5438 for i in \[$]* ; do
5439 case \$i in
5440 (*.orig|*.rej) ;;
5441 (*.[[0-9]]*)
5442         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
5443         if test \$verb = installing ; then
5444         if test ! -d \$cf_subdir\${section} ; then
5445                 mkdir -p \$cf_subdir\$section
5446         fi
5447         fi
5448
5449         # replace variables in man page
5450         if test ! -f $cf_man_alias ; then
5451 cat >>$cf_man_alias <<-CF_EOF2
5452                 s,@DATADIR@,\$datadir,g
5453                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
5454                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
5455                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
5456                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
5457                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
5458                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
5459 CF_EOF
5460         ifelse($1,,,[
5461         for cf_name in $1
5462         do
5463                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
5464                 cf_name=`echo $cf_name|sed "$program_transform_name"`
5465 cat >>$cf_edit_man <<-CF_EOF
5466                 s,@$cf_NAME@,$cf_name,g
5467 CF_EOF
5468         done
5469         ])
5470 cat >>$cf_edit_man <<CF_EOF
5471 CF_EOF2
5472                 echo "...made $cf_man_alias"
5473         fi
5474
5475         aliases=
5476         cf_source=\`basename \$i\`
5477         inalias=\$cf_source
5478         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
5479         if test ! -f \$inalias ; then
5480                 echo .. skipped \$cf_source
5481                 continue
5482         fi
5483 CF_EOF
5484
5485 if test "$MANPAGE_ALIASES" != no ; then
5486 cat >>$cf_edit_man <<CF_EOF
5487         nCurses=ignore.3x
5488         test $with_curses_h = yes && nCurses=ncurses.3x
5489         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
5490 CF_EOF
5491 fi
5492
5493 if test "$MANPAGE_RENAMES" = no ; then
5494 cat >>$cf_edit_man <<CF_EOF
5495         # perform program transformations for section 1 man pages
5496         if test \$section = 1 ; then
5497                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
5498         else
5499                 cf_target=\$cf_subdir\${section}/\$cf_source
5500         fi
5501 CF_EOF
5502 else
5503 cat >>$cf_edit_man <<CF_EOF
5504         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
5505         if test -z "\$cf_target" ; then
5506                 echo '? missing rename for '\$cf_source
5507                 cf_target="\$cf_source"
5508         fi
5509         cf_target="\$cf_subdir\${section}/\${cf_target}"
5510
5511 CF_EOF
5512 fi
5513
5514 cat >>$cf_edit_man <<CF_EOF
5515         sed     -f $cf_man_alias \\
5516 CF_EOF
5517
5518 if test -f $MANPAGE_RENAMES ; then
5519 cat >>$cf_edit_man <<CF_EOF
5520                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
5521 CF_EOF
5522 else
5523 cat >>$cf_edit_man <<CF_EOF
5524                 < \$i >\$TMP
5525 CF_EOF
5526 fi
5527
5528 cat >>$cf_edit_man <<CF_EOF
5529 if test \$cf_tables = yes ; then
5530         tbl \$TMP >\$TMP.out
5531         mv \$TMP.out \$TMP
5532 fi
5533 CF_EOF
5534
5535 if test $with_overwrite != yes ; then
5536 cat >>$cf_edit_man <<CF_EOF
5537         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
5538         mv \$TMP.out \$TMP
5539 CF_EOF
5540 fi
5541
5542 if test $with_curses_h != yes ; then
5543 cat >>$cf_edit_man <<CF_EOF
5544         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
5545         mv \$TMP.out \$TMP
5546 CF_EOF
5547 fi
5548
5549 cat >>$cf_edit_man <<CF_EOF
5550         if test \$form = format ; then
5551                 nroff -man \$TMP >\$TMP.out
5552                 mv \$TMP.out \$TMP
5553         fi
5554 CF_EOF
5555
5556 if test -n "$cf_compress" ; then
5557 cat >>$cf_edit_man <<CF_EOF
5558         if test \$verb = installing ; then
5559         if ( $cf_compress -f \$TMP )
5560         then
5561                 mv \$TMP.$cf_so_strip \$TMP
5562         fi
5563         fi
5564         cf_target="\$cf_target.$cf_so_strip"
5565 CF_EOF
5566 fi
5567
5568 case "$MANPAGE_FORMAT" in
5569 (*BSDI*)
5570 cat >>$cf_edit_man <<CF_EOF
5571         if test \$form = format ; then
5572                 # BSDI installs only .0 suffixes in the cat directories
5573                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
5574         fi
5575 CF_EOF
5576   ;;
5577 esac
5578
5579 cat >>$cf_edit_man <<CF_EOF
5580         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
5581         if test \$verb = installing ; then
5582                 echo \$verb \$cf_target
5583                 \$INSTALL_DATA \$TMP \$cf_target
5584                 test -d \$cf_subdir\${section} &&
5585                 test -n "\$aliases" && (
5586                         cd \$cf_subdir\${section} && (
5587                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
5588                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
5589                                 cf_target=\`basename \$cf_target\`
5590                                 for cf_alias in \$aliases
5591                                 do
5592                                         if test \$section = 1 ; then
5593                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
5594                                         fi
5595
5596                                         if test "$MANPAGE_SYMLINKS" = yes ; then
5597                                                 if test -f \$cf_alias\${suffix} ; then
5598                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
5599                                                         then
5600                                                                 continue
5601                                                         fi
5602                                                 fi
5603                                                 echo .. \$verb alias \$cf_alias\${suffix}
5604 CF_EOF
5605 case "x$LN_S" in
5606 (*-f)
5607 cat >>$cf_edit_man <<CF_EOF
5608                                                 $LN_S \$cf_target \$cf_alias\${suffix}
5609 CF_EOF
5610         ;;
5611 (*)
5612 cat >>$cf_edit_man <<CF_EOF
5613                                                 rm -f \$cf_alias\${suffix}
5614                                                 $LN_S \$cf_target \$cf_alias\${suffix}
5615 CF_EOF
5616         ;;
5617 esac
5618 cat >>$cf_edit_man <<CF_EOF
5619                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
5620                                                 echo ".so \$cf_source" >\$TMP
5621 CF_EOF
5622 if test -n "$cf_compress" ; then
5623 cat >>$cf_edit_man <<CF_EOF
5624                                                 if test -n "$cf_so_strip" ; then
5625                                                         $cf_compress -f \$TMP
5626                                                         mv \$TMP.$cf_so_strip \$TMP
5627                                                 fi
5628 CF_EOF
5629 fi
5630 cat >>$cf_edit_man <<CF_EOF
5631                                                 echo .. \$verb alias \$cf_alias\${suffix}
5632                                                 rm -f \$cf_alias\${suffix}
5633                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
5634                                         fi
5635                                 done
5636                         )
5637                 )
5638         elif test \$verb = removing ; then
5639                 test -f \$cf_target && (
5640                         echo \$verb \$cf_target
5641                         rm -f \$cf_target
5642                 )
5643                 test -d \$cf_subdir\${section} &&
5644                 test -n "\$aliases" && (
5645                         cd \$cf_subdir\${section} && (
5646                                 for cf_alias in \$aliases
5647                                 do
5648                                         if test \$section = 1 ; then
5649                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
5650                                         fi
5651
5652                                         echo .. \$verb alias \$cf_alias\${suffix}
5653                                         rm -f \$cf_alias\${suffix}
5654                                 done
5655                         )
5656                 )
5657         else
5658 #               echo ".hy 0"
5659                 cat \$TMP
5660         fi
5661         ;;
5662 esac
5663 done
5664
5665 if test $cf_inboth = yes ; then
5666 if test \$form != format ; then
5667         $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
5668 fi
5669 fi
5670
5671 exit 0
5672 CF_EOF
5673 chmod 755 $cf_edit_man
5674
5675 ])dnl
5676 dnl ---------------------------------------------------------------------------
5677 dnl CF_MAP_LIB_BASENAME version: 1 updated: 2020/03/07 20:05:14
5678 dnl -------------------
5679 dnl Convert a default-libname to the actual one used via CF_WITH_LIB_BASENAME.
5680 dnl
5681 dnl $1 = variable to set
5682 dnl $2 = default-libname
5683 AC_DEFUN([CF_MAP_LIB_BASENAME],[
5684 CF_UPPER(cf_map_lib_basename,$2)
5685 eval $1=\$${cf_map_lib_basename}_NAME
5686 ])dnl
5687 dnl ---------------------------------------------------------------------------
5688 dnl CF_MATH_LIB version: 9 updated: 2017/01/21 11:06:25
5689 dnl -----------
5690 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
5691 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
5692 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
5693 AC_DEFUN([CF_MATH_LIB],
5694 [
5695 AC_CACHE_CHECK(if -lm needed for math functions,
5696         cf_cv_need_libm,[
5697         AC_TRY_LINK([
5698         #include <stdio.h>
5699         #include <stdlib.h>
5700         #include <math.h>
5701         ],
5702         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
5703         [cf_cv_need_libm=no],
5704         [cf_cv_need_libm=yes])])
5705 if test "$cf_cv_need_libm" = yes
5706 then
5707 ifelse($1,,[
5708         CF_ADD_LIB(m)
5709 ],[$1=-lm])
5710 fi
5711 ])
5712 dnl ---------------------------------------------------------------------------
5713 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
5714 dnl ----------------------
5715 dnl Check if the file-system supports mixed-case filenames.  If we're able to
5716 dnl create a lowercase name and see it as uppercase, it doesn't support that.
5717 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
5718 [
5719 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
5720 if test "$cross_compiling" = yes ; then
5721         case $target_alias in
5722         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
5723                 cf_cv_mixedcase=no
5724                 ;;
5725         (*)
5726                 cf_cv_mixedcase=yes
5727                 ;;
5728         esac
5729 else
5730         rm -f conftest CONFTEST
5731         echo test >conftest
5732         if test -f CONFTEST ; then
5733                 cf_cv_mixedcase=no
5734         else
5735                 cf_cv_mixedcase=yes
5736         fi
5737         rm -f conftest CONFTEST
5738 fi
5739 ])
5740 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
5741 ])dnl
5742 dnl ---------------------------------------------------------------------------
5743 dnl CF_MKSTEMP version: 10 updated: 2017/01/21 11:12:16
5744 dnl ----------
5745 dnl Check for a working mkstemp.  This creates two files, checks that they are
5746 dnl successfully created and distinct (AmigaOS apparently fails on the last).
5747 AC_DEFUN([CF_MKSTEMP],[
5748 AC_CHECK_HEADERS( \
5749 unistd.h \
5750 )
5751 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
5752 rm -rf conftest*
5753 AC_TRY_RUN([
5754 #include <sys/types.h>
5755 #ifdef HAVE_UNISTD_H
5756 #include <unistd.h>
5757 #endif
5758 #include <stdlib.h>
5759 #include <stdio.h>
5760 #include <string.h>
5761 #include <sys/stat.h>
5762 int main(void)
5763 {
5764         char *tmpl = "conftestXXXXXX";
5765         char name[2][80];
5766         int n;
5767         int result = 0;
5768         int fd;
5769         struct stat sb;
5770
5771         umask(077);
5772         for (n = 0; n < 2; ++n) {
5773                 strcpy(name[n], tmpl);
5774                 if ((fd = mkstemp(name[n])) >= 0) {
5775                         if (!strcmp(name[n], tmpl)
5776                          || stat(name[n], &sb) != 0
5777                          || (sb.st_mode & S_IFMT) != S_IFREG
5778                          || (sb.st_mode & 077) != 0) {
5779                                 result = 1;
5780                         }
5781                         close(fd);
5782                 }
5783         }
5784         if (result == 0
5785          && !strcmp(name[0], name[1]))
5786                 result = 1;
5787         ${cf_cv_main_return:-return}(result);
5788 }
5789 ],[cf_cv_func_mkstemp=yes
5790 ],[cf_cv_func_mkstemp=no
5791 ],[cf_cv_func_mkstemp=maybe])
5792 ])
5793 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
5794         AC_CHECK_FUNC(mkstemp)
5795 fi
5796 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
5797         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
5798 fi
5799 ])dnl
5800 dnl ---------------------------------------------------------------------------
5801 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
5802 dnl ----------
5803 dnl Write a debug message to config.log, along with the line number in the
5804 dnl configure script.
5805 AC_DEFUN([CF_MSG_LOG],[
5806 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
5807 ])dnl
5808 dnl ---------------------------------------------------------------------------
5809 dnl CF_NCURSES_ABI_6 version: 3 updated: 2015/06/06 16:10:11
5810 dnl ----------------
5811 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
5812 dnl warn about this.
5813 AC_DEFUN([CF_NCURSES_ABI_6],[
5814 if test "${with_abi_version+set}" != set; then
5815         case $cf_cv_rel_version in
5816         (5.*)
5817                 cf_cv_rel_version=6.0
5818                 cf_cv_abi_version=6
5819                 AC_MSG_WARN(overriding ABI version to $cf_cv_abi_version)
5820                 ;;
5821         esac
5822 fi
5823 ])dnl
5824 dnl ---------------------------------------------------------------------------
5825 dnl CF_NCURSES_WITH_ABI_VERSION version: 2 updated: 2015/12/19 17:51:52
5826 dnl ---------------------------
5827 dnl Allow ncurses's ABI to be overridden.  Generally this happens when a
5828 dnl packager has incremented the ABI past that used in the original package,
5829 dnl and wishes to keep doing this.
5830 dnl
5831 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
5832 dnl symbol.
5833 AC_DEFUN([CF_NCURSES_WITH_ABI_VERSION],[
5834 CF_WITH_ABI_VERSION($1)
5835 if test "x$cf_cv_abi_version" != "x$with_abi_version"
5836 then
5837         case $cf_cv_rel_version in
5838         (5.*)
5839                 cf_cv_rel_version=$with_abi_version.0
5840                 ;;
5841         esac
5842 fi
5843 ])dnl
5844 dnl ---------------------------------------------------------------------------
5845 dnl CF_NO_LEAKS_OPTION version: 6 updated: 2015/04/12 15:39:00
5846 dnl ------------------
5847 dnl see CF_WITH_NO_LEAKS
5848 AC_DEFUN([CF_NO_LEAKS_OPTION],[
5849 AC_MSG_CHECKING(if you want to use $1 for testing)
5850 AC_ARG_WITH($1,
5851         [$2],
5852         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
5853          $4
5854 ])
5855         : ${with_cflags:=-g}
5856         : ${with_no_leaks:=yes}
5857          with_$1=yes],
5858         [with_$1=])
5859 AC_MSG_RESULT(${with_$1:-no})
5860
5861 case .$with_cflags in
5862 (.*-g*)
5863         case .$CFLAGS in
5864         (.*-g*)
5865                 ;;
5866         (*)
5867                 CF_ADD_CFLAGS([-g])
5868                 ;;
5869         esac
5870         ;;
5871 esac
5872 ])dnl
5873 dnl ---------------------------------------------------------------------------
5874 dnl CF_NUMBER_SYNTAX version: 2 updated: 2015/04/17 21:13:04
5875 dnl ----------------
5876 dnl Check if the given variable is a number.  If not, report an error.
5877 dnl $1 is the variable
5878 dnl $2 is the message
5879 AC_DEFUN([CF_NUMBER_SYNTAX],[
5880 if test -n "$1" ; then
5881   case $1 in
5882   ([[0-9]]*)
5883         ;;
5884   (*)
5885         AC_MSG_ERROR($2 is not a number: $1)
5886         ;;
5887   esac
5888 else
5889   AC_MSG_ERROR($2 value is empty)
5890 fi
5891 ])dnl
5892 dnl ---------------------------------------------------------------------------
5893 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
5894 dnl -------------
5895 dnl Compute the object-directory name from the given model name
5896 AC_DEFUN([CF_OBJ_SUBDIR],
5897 [
5898         case $1 in
5899         (libtool) $2='obj_lo'  ;;
5900         (normal)  $2='objects' ;;
5901         (debug)   $2='obj_g' ;;
5902         (profile) $2='obj_p' ;;
5903         (shared)
5904                 case $cf_cv_system_name in
5905                 (cygwin|msys)
5906                         $2='objects' ;;
5907                 (*)
5908                         $2='obj_s' ;;
5909                 esac
5910         esac
5911 ])dnl
5912 dnl ---------------------------------------------------------------------------
5913 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
5914 dnl ----------
5915 dnl Provide a value for the $PATH and similar separator (or amend the value
5916 dnl as provided in autoconf 2.5x).
5917 AC_DEFUN([CF_PATHSEP],
5918 [
5919         AC_MSG_CHECKING(for PATH separator)
5920         case $cf_cv_system_name in
5921         (os2*)  PATH_SEPARATOR=';'  ;;
5922         (*)     ${PATH_SEPARATOR:=':'}  ;;
5923         esac
5924 ifelse([$1],,,[$1=$PATH_SEPARATOR])
5925         AC_SUBST(PATH_SEPARATOR)
5926         AC_MSG_RESULT($PATH_SEPARATOR)
5927 ])dnl
5928 dnl ---------------------------------------------------------------------------
5929 dnl CF_PATH_PROG version: 10 updated: 2019/06/30 19:44:43
5930 dnl ------------
5931 dnl Check for a given program, defining corresponding symbol.
5932 dnl     $1 = environment variable, which is suffixed by "_PATH" in the #define.
5933 dnl     $2 = program name to find.
5934 dnl     $3 = optional list of additional program names to test.
5935 dnl $4 = $PATH
5936 dnl
5937 dnl If there is more than one token in the result, #define the remaining tokens
5938 dnl to $1_ARGS.  We need this for 'install' in particular.
5939 dnl
5940 dnl FIXME: we should allow this to be overridden by environment variables
5941 dnl
5942 AC_DEFUN([CF_PATH_PROG],[
5943 AC_REQUIRE([CF_PATHSEP])
5944 test -z "[$]$1" && $1=$2
5945 AC_PATH_PROGS($1,[$]$1 $2 ifelse($3,,,$3),[$]$1, ifelse($4,,,$4))
5946
5947 cf_path_prog=""
5948 cf_path_args=""
5949 IFS="${IFS:-    }"; cf_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR"
5950 for cf_temp in $ac_cv_path_$1
5951 do
5952         if test -z "$cf_path_prog" ; then
5953                 if test "$with_full_paths" = yes ; then
5954                         CF_PATH_SYNTAX(cf_temp,break)
5955                         cf_path_prog="$cf_temp"
5956                 else
5957                         cf_path_prog="`basename $cf_temp`"
5958                 fi
5959         elif test -z "$cf_path_args" ; then
5960                 cf_path_args="$cf_temp"
5961         else
5962                 cf_path_args="$cf_path_args $cf_temp"
5963         fi
5964 done
5965 IFS="$cf_save_ifs"
5966
5967 if test -n "$cf_path_prog" ; then
5968         CF_MSG_LOG(defining path for ${cf_path_prog})
5969         AC_DEFINE_UNQUOTED($1_PATH,"$cf_path_prog",Define to pathname $1)
5970         test -n "$cf_path_args" && AC_DEFINE_UNQUOTED($1_ARGS,"$cf_path_args",Define to provide args for $1)
5971 fi
5972 ])dnl
5973 dnl ---------------------------------------------------------------------------
5974 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
5975 dnl --------------
5976 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
5977 dnl begins with one of the prefix/exec_prefix variables, and then again if the
5978 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
5979 dnl delayed evaluation of those symbols.
5980 AC_DEFUN([CF_PATH_SYNTAX],[
5981 if test "x$prefix" != xNONE; then
5982         cf_path_syntax="$prefix"
5983 else
5984         cf_path_syntax="$ac_default_prefix"
5985 fi
5986
5987 case ".[$]$1" in
5988 (.\[$]\(*\)*|.\'*\'*)
5989         ;;
5990 (..|./*|.\\*)
5991         ;;
5992 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
5993         ;;
5994 (.\[$]{*prefix}*|.\[$]{*dir}*)
5995         eval $1="[$]$1"
5996         case ".[$]$1" in
5997         (.NONE/*)
5998                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
5999                 ;;
6000         esac
6001         ;;
6002 (.no|.NONE/*)
6003         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
6004         ;;
6005 (*)
6006         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
6007         ;;
6008 esac
6009 ])dnl
6010 dnl ---------------------------------------------------------------------------
6011 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
6012 dnl -------------
6013 dnl Check for the package-config program, unless disabled by command-line.
6014 AC_DEFUN([CF_PKG_CONFIG],
6015 [
6016 AC_MSG_CHECKING(if you want to use pkg-config)
6017 AC_ARG_WITH(pkg-config,
6018         [  --with-pkg-config{=path} enable/disable use of pkg-config],
6019         [cf_pkg_config=$withval],
6020         [cf_pkg_config=yes])
6021 AC_MSG_RESULT($cf_pkg_config)
6022
6023 case $cf_pkg_config in
6024 (no)
6025         PKG_CONFIG=none
6026         ;;
6027 (yes)
6028         CF_ACVERSION_CHECK(2.52,
6029                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
6030                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
6031         ;;
6032 (*)
6033         PKG_CONFIG=$withval
6034         ;;
6035 esac
6036
6037 test -z "$PKG_CONFIG" && PKG_CONFIG=none
6038 if test "$PKG_CONFIG" != none ; then
6039         CF_PATH_SYNTAX(PKG_CONFIG)
6040 elif test "x$cf_pkg_config" != xno ; then
6041         AC_MSG_WARN(pkg-config is not installed)
6042 fi
6043
6044 AC_SUBST(PKG_CONFIG)
6045 ])dnl
6046 dnl ---------------------------------------------------------------------------
6047 dnl CF_POSIX_C_SOURCE version: 11 updated: 2018/12/31 20:46:17
6048 dnl -----------------
6049 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
6050 dnl
6051 dnl     POSIX.1-1990                            _POSIX_SOURCE
6052 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
6053 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
6054 dnl             Bindings Option
6055 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
6056 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
6057 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
6058 dnl
6059 dnl Parameters:
6060 dnl     $1 is the nominal value for _POSIX_C_SOURCE
6061 AC_DEFUN([CF_POSIX_C_SOURCE],
6062 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
6063
6064 if test "$cf_cv_posix_visible" = no; then
6065
6066 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
6067
6068 cf_save_CFLAGS="$CFLAGS"
6069 cf_save_CPPFLAGS="$CPPFLAGS"
6070
6071 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
6072 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
6073
6074 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
6075         CF_MSG_LOG(if the symbol is already defined go no further)
6076         AC_TRY_COMPILE([#include <sys/types.h>],[
6077 #ifndef _POSIX_C_SOURCE
6078 make an error
6079 #endif],
6080         [cf_cv_posix_c_source=no],
6081         [cf_want_posix_source=no
6082          case .$cf_POSIX_C_SOURCE in
6083          (.[[12]]??*)
6084                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
6085                 ;;
6086          (.2)
6087                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
6088                 cf_want_posix_source=yes
6089                 ;;
6090          (.*)
6091                 cf_want_posix_source=yes
6092                 ;;
6093          esac
6094          if test "$cf_want_posix_source" = yes ; then
6095                 AC_TRY_COMPILE([#include <sys/types.h>],[
6096 #ifdef _POSIX_SOURCE
6097 make an error
6098 #endif],[],
6099                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
6100          fi
6101          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
6102          CFLAGS="$cf_trim_CFLAGS"
6103          CPPFLAGS="$cf_trim_CPPFLAGS"
6104          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
6105          CF_MSG_LOG(if the second compile does not leave our definition intact error)
6106          AC_TRY_COMPILE([#include <sys/types.h>],[
6107 #ifndef _POSIX_C_SOURCE
6108 make an error
6109 #endif],,
6110          [cf_cv_posix_c_source=no])
6111          CFLAGS="$cf_save_CFLAGS"
6112          CPPFLAGS="$cf_save_CPPFLAGS"
6113         ])
6114 ])
6115
6116 if test "$cf_cv_posix_c_source" != no ; then
6117         CFLAGS="$cf_trim_CFLAGS"
6118         CPPFLAGS="$cf_trim_CPPFLAGS"
6119         CF_ADD_CFLAGS($cf_cv_posix_c_source)
6120 fi
6121
6122 fi # cf_cv_posix_visible
6123
6124 ])dnl
6125 dnl ---------------------------------------------------------------------------
6126 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
6127 dnl ----------------
6128 dnl POSIX documents test-macros which an application may set before any system
6129 dnl headers are included to make features available.
6130 dnl
6131 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
6132 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
6133 dnl recent features visible in the system header files unless the application
6134 dnl overrides the corresponding test-macros.  Doing that introduces portability
6135 dnl problems.
6136 dnl
6137 dnl This macro makes a special check for the symbols used for this, to avoid a
6138 dnl conflicting definition.
6139 AC_DEFUN([CF_POSIX_VISIBLE],
6140 [
6141 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
6142 AC_TRY_COMPILE([#include <stdio.h>],[
6143 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
6144         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
6145         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
6146         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
6147 #error conflicting symbols found
6148 #endif
6149 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
6150 ])
6151 ])dnl
6152 dnl ---------------------------------------------------------------------------
6153 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
6154 dnl ------------
6155 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
6156 dnl
6157 dnl $1 = symbol to test
6158 dnl $2 = value (if any) to use for a predefinition
6159 AC_DEFUN([CF_PREDEFINE],
6160 [
6161 AC_MSG_CHECKING(if we must define $1)
6162 AC_TRY_COMPILE([#include <sys/types.h>
6163 ],[
6164 #ifndef $1
6165 make an error
6166 #endif],[cf_result=no],[cf_result=yes])
6167 AC_MSG_RESULT($cf_result)
6168
6169 if test "$cf_result" = yes ; then
6170         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
6171 elif test "x$2" != "x" ; then
6172         AC_MSG_CHECKING(checking for compatible value versus $2)
6173         AC_TRY_COMPILE([#include <sys/types.h>
6174 ],[
6175 #if $1-$2 < 0
6176 make an error
6177 #endif],[cf_result=yes],[cf_result=no])
6178         AC_MSG_RESULT($cf_result)
6179         if test "$cf_result" = no ; then
6180                 # perhaps we can override it - try...
6181                 CPPFLAGS="$CPPFLAGS -D$1=$2"
6182         fi
6183 fi
6184 ])dnl
6185 dnl ---------------------------------------------------------------------------
6186 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
6187 dnl ------------
6188 dnl Append definitions and rules for the given programs to the subdirectory
6189 dnl Makefiles, and the recursion rule for the top-level Makefile.
6190 dnl
6191 dnl parameters
6192 dnl     $1 = script to run
6193 dnl     $2 = list of subdirectories
6194 dnl
6195 dnl variables
6196 dnl     $AWK
6197 AC_DEFUN([CF_PRG_RULES],
6198 [
6199 for cf_dir in $2
6200 do
6201         if test ! -d $srcdir/$cf_dir; then
6202                 continue
6203         elif test -f $srcdir/$cf_dir/programs; then
6204                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
6205         fi
6206 done
6207
6208 ])dnl
6209 dnl ---------------------------------------------------------------------------
6210 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
6211 dnl ----------
6212 dnl Check for archiver "ar".
6213 AC_DEFUN([CF_PROG_AR],[
6214 AC_CHECK_TOOL(AR, ar, ar)
6215 ])
6216 dnl ---------------------------------------------------------------------------
6217 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
6218 dnl -----------
6219 dnl Check for awk, ensure that the check found something.
6220 AC_DEFUN([CF_PROG_AWK],
6221 [
6222 AC_PROG_AWK
6223 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
6224 ])dnl
6225 dnl ---------------------------------------------------------------------------
6226 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
6227 dnl ----------
6228 dnl standard check for CC, plus followup sanity checks
6229 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
6230 AC_DEFUN([CF_PROG_CC],[
6231 CF_ACVERSION_CHECK(2.53,
6232         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
6233          AC_REQUIRE([AC_PROG_CC])],
6234         [])
6235 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
6236 CF_GCC_VERSION
6237 CF_ACVERSION_CHECK(2.52,
6238         [AC_PROG_CC_STDC],
6239         [CF_ANSI_CC_REQD])
6240 CF_CC_ENV_FLAGS
6241 ])dnl
6242 dnl ---------------------------------------------------------------------------
6243 dnl CF_PROG_CC_C_O version: 5 updated: 2017/01/21 11:06:25
6244 dnl --------------
6245 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
6246 dnl the output file can be renamed, and allows for a shell variable that can
6247 dnl be used later.  The parameter is either CC or CXX.  The result is the
6248 dnl cache variable:
6249 dnl     $cf_cv_prog_CC_c_o
6250 dnl     $cf_cv_prog_CXX_c_o
6251 dnl
6252 dnl $1 = compiler
6253 dnl $2 = compiler options, if any
6254 AC_DEFUN([CF_PROG_CC_C_O],
6255 [AC_REQUIRE([AC_PROG_CC])dnl
6256 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
6257 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
6258 [
6259 cat > conftest.$ac_ext <<CF_EOF
6260 int main(void)
6261 {
6262         ${cf_cv_main_return:-return}(0);
6263 }
6264 CF_EOF
6265 # We do the test twice because some compilers refuse to overwrite an
6266 # existing .o file with -o, though they will create one.
6267 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
6268 if AC_TRY_EVAL(ac_try) &&
6269   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
6270 then
6271   eval cf_cv_prog_$1_c_o=yes
6272 else
6273   eval cf_cv_prog_$1_c_o=no
6274 fi
6275 rm -rf conftest*
6276 ])dnl
6277 if test $cf_cv_prog_$1_c_o = yes; then
6278   AC_MSG_RESULT([yes])
6279 else
6280   AC_MSG_RESULT([no])
6281 fi
6282 ])dnl
6283 dnl ---------------------------------------------------------------------------
6284 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
6285 dnl -------------
6286 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
6287 dnl This macro adds a check to ensure the script found something.
6288 AC_DEFUN([CF_PROG_EGREP],
6289 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
6290         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
6291                 then ac_cv_prog_egrep='grep -E'
6292                 else ac_cv_prog_egrep='egrep'
6293         fi])
6294         EGREP=$ac_cv_prog_egrep
6295         AC_SUBST([EGREP])
6296         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
6297 ])dnl
6298 dnl ---------------------------------------------------------------------------
6299 dnl CF_PROG_GNAT version: 10 updated: 2019/12/31 08:53:54
6300 dnl ------------
6301 dnl Check for gnat/gnatmake/etc, ensure that the toolset is complete.
6302 AC_DEFUN([CF_PROG_GNAT],[
6303 for cf_prog_gnat in gnat gnatmake gprconfig gprbuild
6304 do
6305         CF_UPPER(cf_upper_prog_gnat,${cf_prog_gnat})
6306
6307         unset ac_cv_path_cf_TEMP_gnat
6308         unset cf_TEMP_gnat
6309         AC_PATH_PROG(cf_TEMP_gnat,$cf_prog_gnat,no)
6310         eval cf_cv_PATH_$cf_upper_prog_gnat=[$]ac_cv_path_cf_TEMP_gnat
6311
6312         if test "x$cf_TEMP_gnat" != xno; then
6313                 unset cf_cv_gnat_version
6314                 unset cf_TEMP_gnat
6315                 CF_GNAT_VERSION(cf_TEMP_gnat,$cf_prog_gnat)
6316         fi
6317         eval cf_cv_VERSION_$cf_upper_prog_gnat=[$]cf_TEMP_gnat
6318
6319         unset cf_TEMP_gnat
6320         unset cf_cv_gnat_version
6321         unset ac_cv_path_cf_TEMP_gnat
6322 done
6323
6324 if test "x$cf_cv_VERSION_GNATMAKE" = "xno"; then
6325         cf_ada_make=
6326         cf_cv_prog_gnat_correct=no
6327 else
6328         cf_ada_make=gnatmake
6329         if test "x$cf_cv_VERSION_GPRCONFIG" = "xno"; then
6330                 # gprconfig is newer than gnatmake; we can continue...
6331                 cf_ada_config="##"
6332         else
6333                 rm -rf conftest* *~conftest*
6334                 if mkdir conftest.src
6335                 then
6336                         cf_ada_config=""
6337                         cd conftest.src
6338                         for cf_gprconfig in Ada C
6339                         do
6340                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
6341                                 if test $cf_gprconfig = C
6342                                 then
6343                                         for cf_gprconfig_param in \
6344                                                 $cf_gprconfig,,,,GNATGCC \
6345                                                 $cf_gprconfig,,,,GCC \
6346                                                 $cf_gprconfig
6347                                         do
6348                                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6349                                                 test -n "$cf_gprconfig_value" && break
6350                                         done
6351                                 else
6352                                         cf_gprconfig_param=$cf_gprconfig
6353                                         cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6354                                 fi
6355                                 if test -n "$cf_gprconfig_value"
6356                                 then
6357                                         eval cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value
6358                                         AC_MSG_RESULT($cf_gprconfig_value)
6359                                 else
6360                                         AC_MSG_RESULT(missing)
6361                                         cf_ada_config="#"
6362                                         break
6363                                 fi
6364                         done
6365                         cd ..
6366                         rm -rf conftest* *~conftest*
6367                 fi
6368         fi
6369         if test "x$cf_ada_config" != "x#"
6370         then
6371                 CF_GNAT_VERSION
6372                 CF_CHECK_GNAT_VERSION
6373                 AC_CHECK_PROG(M4_exists, m4, yes, no)
6374                 if test "$ac_cv_prog_M4_exists" = no; then
6375                         cf_cv_prog_gnat_correct=no
6376                         AC_MSG_WARN(Ada95 binding required program m4 not found. Ada95 binding disabled)
6377                 fi
6378                 if test "$cf_cv_prog_gnat_correct" = yes; then
6379                         AC_MSG_CHECKING(if GNAT works)
6380                         CF_GNAT_TRY_RUN([procedure conftest;],
6381 [with Text_IO;
6382 with GNAT.OS_Lib;
6383 procedure conftest is
6384 begin
6385    Text_IO.Put ("Hello World");
6386    Text_IO.New_Line;
6387    GNAT.OS_Lib.OS_Exit (0);
6388 end conftest;],
6389 [cf_cv_prog_gnat_correct=yes],
6390 [cf_cv_prog_gnat_correct=no])
6391                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
6392                 fi
6393         else
6394                 cf_cv_prog_gnat_correct=no
6395         fi
6396 fi
6397
6398 AC_SUBST(cf_ada_make)
6399 AC_SUBST(cf_ada_config)
6400 AC_SUBST(cf_ada_config_Ada)
6401 AC_SUBST(cf_ada_config_C)
6402 ])dnl
6403 dnl ---------------------------------------------------------------------------
6404 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
6405 dnl ---------------
6406 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
6407 dnl misc/tabset install won't work properly.  Usually this happens only when
6408 dnl using the fallback mkinstalldirs script
6409 AC_DEFUN([CF_PROG_INSTALL],
6410 [AC_PROG_INSTALL
6411 case $INSTALL in
6412 (/*)
6413         ;;
6414 (*)
6415         CF_DIRNAME(cf_dir,$INSTALL)
6416         test -z "$cf_dir" && cf_dir=.
6417         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
6418         ;;
6419 esac
6420 ])dnl
6421 dnl ---------------------------------------------------------------------------
6422 dnl CF_PROG_LDCONFIG version: 5 updated: 2015/04/18 08:56:57
6423 dnl ----------------
6424 dnl Check for ldconfig, needed to fixup shared libraries that would be built
6425 dnl and then used in the install.
6426 AC_DEFUN([CF_PROG_LDCONFIG],[
6427 if test "$cross_compiling" = yes ; then
6428         LDCONFIG=:
6429 else
6430         case "$cf_cv_system_name" in
6431         (dragonfly*|mirbsd*|freebsd*)
6432                 test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
6433                 ;;
6434         (*) LDPATH=$PATH:/sbin:/usr/sbin
6435                 AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
6436                 ;;
6437         esac
6438 fi
6439 AC_SUBST(LDCONFIG)
6440 ])dnl
6441 dnl ---------------------------------------------------------------------------
6442 dnl CF_PROG_LINT version: 4 updated: 2019/11/20 18:55:37
6443 dnl ------------
6444 AC_DEFUN([CF_PROG_LINT],
6445 [
6446 AC_CHECK_PROGS(LINT, lint cppcheck splint)
6447 case "x$LINT" in
6448 (xcppcheck|x*/cppcheck)
6449         test -z "$LINT_OPTS" && LINT_OPTS="--enable=all"
6450         ;;
6451 esac
6452 AC_SUBST(LINT_OPTS)
6453 ])dnl
6454 dnl ---------------------------------------------------------------------------
6455 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
6456 dnl ------------
6457 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
6458 dnl option if it is supported.
6459 AC_DEFUN([CF_PROG_LN_S],[
6460 AC_PROG_LN_S
6461 AC_MSG_CHECKING(if $LN_S -f options work)
6462
6463 rm -f conf$$.src conf$$dst
6464 echo >conf$$.dst
6465 echo first >conf$$.src
6466 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
6467         cf_prog_ln_sf=yes
6468 else
6469         cf_prog_ln_sf=no
6470 fi
6471 rm -f conf$$.dst conf$$src
6472 AC_MSG_RESULT($cf_prog_ln_sf)
6473
6474 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
6475 ])dnl
6476 dnl ---------------------------------------------------------------------------
6477 dnl CF_REGEX version: 16 updated: 2020/09/26 19:56:36
6478 dnl --------
6479 dnl Attempt to determine if we've got one of the flavors of regular-expression
6480 dnl code that we can support.
6481 AC_DEFUN([CF_REGEX],
6482 [
6483
6484 cf_regex_func=no
6485 cf_regex_libs=
6486 case $host_os in
6487 (mingw*)
6488         # -lsystre -ltre -lintl -liconv
6489         AC_CHECK_LIB(systre,regcomp,[
6490                 AC_CHECK_LIB(iconv,libiconv_open,[CF_ADD_LIB(iconv)])
6491                 AC_CHECK_LIB(intl,libintl_gettext,[CF_ADD_LIB(intl)])
6492                 AC_CHECK_LIB(tre,tre_regcomp,[CF_ADD_LIB(tre)])
6493                 CF_ADD_LIB(systre)
6494                 cf_regex_func=regcomp
6495         ],[
6496                 AC_CHECK_LIB(gnurx,regcomp,[
6497                         CF_ADD_LIB(gnurx)
6498                         cf_regex_func=regcomp])
6499         ])
6500         ;;
6501 (*)
6502         cf_regex_libs="regex re"
6503         AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
6504                 for cf_regex_lib in $cf_regex_libs
6505                 do
6506                         AC_CHECK_LIB($cf_regex_lib,regcomp,[
6507                                         CF_ADD_LIB($cf_regex_lib)
6508                                         cf_regex_func=regcomp
6509                                         break])
6510                 done
6511         ])
6512         ;;
6513 esac
6514
6515 if test "$cf_regex_func" = no ; then
6516         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
6517                 AC_CHECK_LIB(gen,compile,[
6518                                 CF_ADD_LIB(gen)
6519                                 cf_regex_func=compile])])
6520 fi
6521
6522 if test "$cf_regex_func" = no ; then
6523         AC_MSG_WARN(cannot find regular expression library)
6524 fi
6525
6526 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
6527
6528 cf_cv_regex_hdrs=no
6529 case $cf_regex_func in
6530 (compile)
6531         for cf_regex_hdr in regexp.h regexpr.h
6532         do
6533                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
6534                         char *p = compile("", "", "", 0);
6535                         int x = step("", "");
6536                         (void)p;
6537                         (void)x;
6538                 ],[
6539                         cf_cv_regex_hdrs=$cf_regex_hdr
6540                         break
6541                 ])
6542         done
6543         ;;
6544 (*)
6545         for cf_regex_hdr in regex.h
6546         do
6547                 AC_TRY_LINK([#include <sys/types.h>
6548 #include <$cf_regex_hdr>],[
6549                         regex_t *p = 0;
6550                         int x = regcomp(p, "", 0);
6551                         int y = regexec(p, "", 0, 0, 0);
6552                         (void)x;
6553                         (void)y;
6554                         regfree(p);
6555                 ],[
6556                         cf_cv_regex_hdrs=$cf_regex_hdr
6557                         break
6558                 ])
6559         done
6560         ;;
6561 esac
6562
6563 ])
6564
6565 case $cf_cv_regex_hdrs in
6566         (no)            AC_MSG_WARN(no regular expression header found) ;;
6567         (regex.h)       AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;;
6568         (regexp.h)      AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;;
6569         (regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
6570 esac
6571 ])dnl
6572 dnl ---------------------------------------------------------------------------
6573 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
6574 dnl ----------------
6575 dnl Remove all -U and -D options that refer to the given symbol from a list
6576 dnl of C compiler options.  This works around the problem that not all
6577 dnl compilers process -U and -D options from left-to-right, so a -U option
6578 dnl cannot be used to cancel the effect of a preceding -D option.
6579 dnl
6580 dnl $1 = target (which could be the same as the source variable)
6581 dnl $2 = source (including '$')
6582 dnl $3 = symbol to remove
6583 define([CF_REMOVE_DEFINE],
6584 [
6585 $1=`echo "$2" | \
6586         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
6587                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
6588 ])dnl
6589 dnl ---------------------------------------------------------------------------
6590 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
6591 dnl -------------
6592 dnl Remove the given library from the symbol
6593 dnl
6594 dnl $1 = target (which could be the same as the source variable)
6595 dnl $2 = source (including '$')
6596 dnl $3 = library to remove
6597 define([CF_REMOVE_LIB],
6598 [
6599 # remove $3 library from $2
6600 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
6601 ])dnl
6602 dnl ---------------------------------------------------------------------------
6603 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
6604 dnl ---------------------
6605 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
6606 dnl $1 = name of current macro
6607 define([CF_RESTORE_XTRA_FLAGS],
6608 [
6609 LIBS="$cf_save_LIBS_$1"
6610 CFLAGS="$cf_save_CFLAGS_$1"
6611 CPPFLAGS="$cf_save_CPPFLAGS_$1"
6612 ])dnl
6613 dnl ---------------------------------------------------------------------------
6614 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
6615 dnl -------------
6616 AC_DEFUN([CF_RPATH_HACK],
6617 [
6618 AC_REQUIRE([CF_LD_RPATH_OPT])
6619 AC_MSG_CHECKING(for updated LDFLAGS)
6620 if test -n "$LD_RPATH_OPT" ; then
6621         AC_MSG_RESULT(maybe)
6622
6623         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
6624         cf_rpath_list="/usr/lib /lib"
6625         if test "$cf_ldd_prog" != no
6626         then
6627                 cf_rpath_oops=
6628
6629 AC_TRY_LINK([#include <stdio.h>],
6630                 [printf("Hello");],
6631                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
6632                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
6633
6634                 # If we passed the link-test, but get a "not found" on a given library,
6635                 # this could be due to inept reconfiguration of gcc to make it only
6636                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
6637                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
6638                 # /usr/local libraries.
6639                 if test -n "$cf_rpath_oops"
6640                 then
6641                         for cf_rpath_src in $cf_rpath_oops
6642                         do
6643                                 for cf_rpath_dir in \
6644                                         /usr/local \
6645                                         /usr/pkg \
6646                                         /opt/sfw
6647                                 do
6648                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
6649                                         then
6650                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
6651                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
6652                                                 break
6653                                         fi
6654                                 done
6655                         done
6656                 fi
6657         fi
6658
6659         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
6660
6661         CF_RPATH_HACK_2(LDFLAGS)
6662         CF_RPATH_HACK_2(LIBS)
6663
6664         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
6665 else
6666         AC_MSG_RESULT(no)
6667 fi
6668 AC_SUBST(EXTRA_LDFLAGS)
6669 ])dnl
6670 dnl ---------------------------------------------------------------------------
6671 dnl CF_RPATH_HACK_2 version: 7 updated: 2015/04/12 15:39:00
6672 dnl ---------------
6673 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
6674 dnl EXTRA_LDFLAGS for each -L option found.
6675 dnl
6676 dnl $cf_rpath_list contains a list of directories to ignore.
6677 dnl
6678 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
6679 dnl      but LIBS often has misplaced -L options.
6680 AC_DEFUN([CF_RPATH_HACK_2],
6681 [
6682 CF_VERBOSE(...checking $1 [$]$1)
6683
6684 cf_rpath_dst=
6685 for cf_rpath_src in [$]$1
6686 do
6687         case $cf_rpath_src in
6688         (-L*)
6689
6690                 # check if this refers to a directory which we will ignore
6691                 cf_rpath_skip=no
6692                 if test -n "$cf_rpath_list"
6693                 then
6694                         for cf_rpath_item in $cf_rpath_list
6695                         do
6696                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
6697                                 then
6698                                         cf_rpath_skip=yes
6699                                         break
6700                                 fi
6701                         done
6702                 fi
6703
6704                 if test "$cf_rpath_skip" = no
6705                 then
6706                         # transform the option
6707                         if test "$LD_RPATH_OPT" = "-R " ; then
6708                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
6709                         else
6710                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
6711                         fi
6712
6713                         # if we have not already added this, add it now
6714                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
6715                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
6716                         then
6717                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
6718                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
6719                         fi
6720                 fi
6721                 ;;
6722         esac
6723         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
6724 done
6725 $1=$cf_rpath_dst
6726
6727 CF_VERBOSE(...checked $1 [$]$1)
6728 AC_SUBST(EXTRA_LDFLAGS)
6729 ])dnl
6730 dnl ---------------------------------------------------------------------------
6731 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
6732 dnl ------------------
6733 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
6734 dnl and libraries which do not update those variables.
6735 dnl
6736 dnl $1 = name of current macro
6737 define([CF_SAVE_XTRA_FLAGS],
6738 [
6739 cf_save_LIBS_$1="$LIBS"
6740 cf_save_CFLAGS_$1="$CFLAGS"
6741 cf_save_CPPFLAGS_$1="$CPPFLAGS"
6742 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
6743 for cf_X_CFLAGS in $X_CFLAGS
6744 do
6745         case "x$cf_X_CFLAGS" in
6746         x-[[IUD]]*)
6747                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
6748                 ;;
6749         *)
6750                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
6751                 ;;
6752         esac
6753 done
6754 ])dnl
6755 dnl ---------------------------------------------------------------------------
6756 dnl CF_SHARED_OPTS version: 102 updated: 2020/08/22 18:17:19
6757 dnl --------------
6758 dnl --------------
6759 dnl Attempt to determine the appropriate CC/LD options for creating a shared
6760 dnl library.
6761 dnl
6762 dnl Notes:
6763 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
6764 dnl the build-tree, i.e., by making use of the libraries that are compiled in
6765 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
6766 dnl shared library since that can lead to unexpected results at runtime.
6767 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
6768 dnl libraries are compiled in ../../lib
6769 dnl
6770 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
6771 dnl to install symbolic links to the rel/abi versions of shared libraries.
6772 dnl
6773 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
6774 dnl version when making symbolic links.
6775 dnl
6776 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
6777 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
6778 dnl (ex: libncurses.so.<ver>).
6779 dnl
6780 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
6781 AC_DEFUN([CF_SHARED_OPTS],
6782 [
6783         AC_REQUIRE([CF_LD_RPATH_OPT])
6784
6785         RM_SHARED_OPTS=
6786         LOCAL_LDFLAGS=
6787         LOCAL_LDFLAGS2=
6788         LD_SHARED_OPTS=
6789         INSTALL_LIB="-m 644"
6790         : ${rel_builddir:=.}
6791
6792         shlibdir=$libdir
6793         AC_SUBST(shlibdir)
6794
6795         MAKE_DLLS="#"
6796         AC_SUBST(MAKE_DLLS)
6797
6798         cf_cv_do_symlinks=no
6799         cf_ld_rpath_opt=
6800         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
6801
6802         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
6803         AC_ARG_WITH(shlib-version,
6804         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
6805         [test -z "$withval" && withval=auto
6806         case $withval in
6807         (yes)
6808                 cf_cv_shlib_version=auto
6809                 ;;
6810         (rel|abi|auto)
6811                 cf_cv_shlib_version=$withval
6812                 ;;
6813         (*)
6814                 AC_MSG_RESULT($withval)
6815                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
6816                 ;;
6817         esac
6818         ],[cf_cv_shlib_version=auto])
6819         AC_MSG_RESULT($cf_cv_shlib_version)
6820
6821         cf_cv_rm_so_locs=no
6822         cf_try_cflags=
6823
6824         # Some less-capable ports of gcc support only -fpic
6825         CC_SHARED_OPTS=
6826
6827         cf_try_fPIC=no
6828         if test "$GCC" = yes
6829         then
6830                 cf_try_fPIC=yes
6831         else
6832                 case $cf_cv_system_name in
6833                 (*linux*)       # e.g., PGI compiler
6834                         cf_try_fPIC=yes
6835                         ;;
6836                 esac
6837         fi
6838
6839         if test "$cf_try_fPIC" = yes
6840         then
6841                 AC_MSG_CHECKING(which $CC option to use)
6842                 cf_save_CFLAGS="$CFLAGS"
6843                 for CC_SHARED_OPTS in -fPIC -fpic ''
6844                 do
6845                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
6846                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
6847                 done
6848                 AC_MSG_RESULT($CC_SHARED_OPTS)
6849                 CFLAGS="$cf_save_CFLAGS"
6850         fi
6851
6852         cf_cv_shlib_version_infix=no
6853
6854         case $cf_cv_system_name in
6855         (aix4.[3-9]*|aix[[5-7]]*)
6856                 if test "$GCC" = yes; then
6857                         CC_SHARED_OPTS='-Wl,-brtl'
6858                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
6859                 else
6860                         CC_SHARED_OPTS='-brtl'
6861                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
6862                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
6863                 fi
6864                 ;;
6865         (beos*)
6866                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
6867                 ;;
6868         (cygwin*)
6869                 CC_SHARED_OPTS=
6870                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6871                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6872                 cf_cv_shlib_version=cygdll
6873                 cf_cv_shlib_version_infix=cygdll
6874                 shlibdir=$bindir
6875                 MAKE_DLLS=
6876                 cat >mk_shared_lib.sh <<-CF_EOF
6877                 #!$SHELL
6878                 SHARED_LIB=\[$]1
6879                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6880                 shift
6881                 cat <<-EOF
6882                 Linking shared library
6883                 ** SHARED_LIB \[$]SHARED_LIB
6884                 ** IMPORT_LIB \[$]IMPORT_LIB
6885 EOF
6886                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6887 CF_EOF
6888                 chmod +x mk_shared_lib.sh
6889                 ;;
6890         (msys*)
6891                 CC_SHARED_OPTS=
6892                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6893                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6894                 cf_cv_shlib_version=msysdll
6895                 cf_cv_shlib_version_infix=msysdll
6896                 shlibdir=$bindir
6897                 MAKE_DLLS=
6898                 cat >mk_shared_lib.sh <<-CF_EOF
6899                 #!$SHELL
6900                 SHARED_LIB=\[$]1
6901                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6902                 shift
6903                 cat <<-EOF
6904                 Linking shared library
6905                 ** SHARED_LIB \[$]SHARED_LIB
6906                 ** IMPORT_LIB \[$]IMPORT_LIB
6907 EOF
6908                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6909 CF_EOF
6910                 chmod +x mk_shared_lib.sh
6911                 ;;
6912         (darwin*)
6913                 cf_try_cflags="no-cpp-precomp"
6914                 CC_SHARED_OPTS="-dynamic"
6915                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
6916                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
6917                 cf_cv_shlib_version_infix=yes
6918                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
6919                         cf_save_LDFLAGS=$LDFLAGS
6920                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
6921                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
6922                                 LDFLAGS=$cf_save_LDFLAGS])
6923                 if test $cf_cv_ldflags_search_paths_first = yes; then
6924                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
6925                 fi
6926                 ;;
6927         (hpux[[7-8]]*)
6928                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
6929                 if test "$GCC" != yes; then
6930                         CC_SHARED_OPTS='+Z'
6931                 fi
6932                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
6933                 INSTALL_LIB="-m 555"
6934                 ;;
6935         (hpux*)
6936                 # (tested with gcc 2.7.2 -- I don't have c89)
6937                 if test "$GCC" = yes; then
6938                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
6939                 else
6940                         CC_SHARED_OPTS='+Z'
6941                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
6942                 fi
6943                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
6944                 # HP-UX shared libraries must be executable, and should be
6945                 # readonly to exploit a quirk in the memory manager.
6946                 INSTALL_LIB="-m 555"
6947                 ;;
6948         (interix*)
6949                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6950                 if test "$cf_cv_shlib_version" = rel; then
6951                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
6952                 else
6953                         cf_shared_soname='`basename $[@]`'
6954                 fi
6955                 CC_SHARED_OPTS=
6956                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
6957                 ;;
6958         (irix*)
6959                 if test "$cf_cv_enable_rpath" = yes ; then
6960                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6961                 fi
6962                 # tested with IRIX 5.2 and 'cc'.
6963                 if test "$GCC" != yes; then
6964                         CC_SHARED_OPTS='-KPIC'
6965                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
6966                 else
6967                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
6968                 fi
6969                 cf_cv_rm_so_locs=yes
6970                 ;;
6971         (linux*|gnu*|k*bsd*-gnu)
6972                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
6973                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
6974                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6975                 fi
6976                 if test "$cf_cv_enable_rpath" = yes ; then
6977                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6978                 fi
6979                 CF_SHARED_SONAME
6980                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
6981                 ;;
6982         (mingw*msvc*)
6983                 cf_cv_shlib_version=msvcdll
6984                 cf_cv_shlib_version_infix=msvcdll
6985                 shlibdir=$bindir
6986                 MAKE_DLLS=
6987                 if test "$DFT_LWR_MODEL" = "shared" ; then
6988                         LOCAL_LDFLAGS="-link -dll"
6989                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6990                         EXTRA_LDFLAGS="-link -dll $EXTRA_LDFLAGS"
6991                 fi
6992                 CC_SHARED_OPTS=
6993                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ ${LD} [$]{CFLAGS}'
6994                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.lib"
6995                 cat >mk_shared_lib.sh <<-CF_EOF
6996                 #!$SHELL
6997                 SHARED_LIB=\[$]1
6998                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.lib/'\`
6999                 shift
7000                 my_ld=\[$]1
7001                 shift
7002                 cat <<-EOF
7003                 Linking shared library
7004                 ** SHARED LIB \$SHARED_LIB
7005                 ** IMPORT_LIB \$IMPORT_LIB
7006 EOF
7007                 args=\$(echo \[$]* | sed -E "s#-l(\w*)#\1.dll.lib#g" | sed -E "s#-L(\w*)#-LIBPATH:\1#g")
7008                 exec \$my_ld -DLL -IMPLIB:"\${IMPORT_LIB}" -OUT:"\${SHARED_LIB}" ${LDFLAGS} \$args
7009                 mv "\${IMPORT_LIB}" "\${IMPORT_LIB}"
7010 CF_EOF
7011                 chmod +x mk_shared_lib.sh
7012                 cat >mk_prog.sh <<-CF_EOF
7013                 #!$SHELL
7014                 shift
7015                 # Ignore first argument (compiler) and use LD (link.exe) unconditionally
7016                 LD="[$]LD"
7017                 clopts=()
7018                 ldopts=("/subsystem:console")
7019                 libs=()
7020                 isdll=0
7021                 while test \[$]# -gt 0; do
7022                         case "\[$]1" in
7023                                 -link)
7024                                         # ignore -link argument
7025                                         ;;
7026                                 -M[[TD]] | -M[[TD]]d)
7027                                         # ignore runtime-library option
7028                                         ;;
7029                                 -dll)
7030                                         isdll=1
7031                                         ;;
7032                                 -W* | -w*)
7033                                         # ignore warnings
7034                                         ;;
7035                                 -D*)
7036                                         clopts+=("\[$]1")
7037                                         ;;
7038                                 -I*)
7039                                         clopts+=("\[$]1")
7040                                         ;;
7041                                 -l*)
7042                                         libs+=("\`echo \"\[$]1\" | sed \"s/^-l//\"\`")
7043                                         ;;
7044                                 -L*)
7045                                         ldopts+=("\`echo \"\[$]1\" | sed \"s/^-L/-LIBPATH:/\"\`")
7046                                         ;;
7047                                 *.obj | *.o)
7048                                         ldopts+=("\[$]1")
7049                                         ;;
7050                                 -Wl,*)
7051                                         for linkarg in \`echo '\[$]1' | sed -e 's/-Wl,//' -e 's/,/ /'\`; do
7052                                                 ldopts+=("\[$]{linkarg}")
7053                                         done
7054                                         ;;
7055                                 *.lib)
7056                                         ldopts+=("\[$]1")
7057                                         ;;
7058                                 -o)
7059                                         shift
7060                                         ldopts+=("-out:\[$]1")
7061                                         ;;
7062                                 *)
7063                                         clopts+=("\[$]1")
7064                                         ldopts+=("\[$]1")
7065                                         ;;
7066                         esac
7067                         shift
7068                 done
7069                 if [[ "\$isdll" -ne 0 ]]; then
7070                         for lib in \[$]{libs[[*]]}; do
7071                                 ldopts+=("\[$]lib.dll.lib")
7072                         done
7073                 else
7074                         for lib in \[$]{libs[[*]]}; do
7075                                 ldopts+=("\[$]lib.lib")
7076                         done
7077                 fi
7078                 cat <<-EOF
7079                 Creating program
7080                 ** ld options:   "\[$]{ldopts[[@]]}"
7081 EOF
7082                 exec \[$]LD \[$]{ldopts[[@]]}
7083 CF_EOF
7084                 chmod +x mk_prog.sh
7085                 LINK_PROGS="$SHELL ${rel_builddir}/mk_prog.sh"
7086                 LINK_TESTS="$SHELL ${rel_builddir}/mk_prog.sh"
7087                 ;;
7088         (mingw*)
7089                 cf_cv_shlib_version=mingw
7090                 cf_cv_shlib_version_infix=mingw
7091                 shlibdir=$bindir
7092                 MAKE_DLLS=
7093                 if test "$DFT_LWR_MODEL" = "shared" ; then
7094                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
7095                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7096                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
7097                 fi
7098                 CC_SHARED_OPTS=
7099                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
7100                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
7101                 cat >mk_shared_lib.sh <<-CF_EOF
7102                 #!$SHELL
7103                 SHARED_LIB=\[$]1
7104                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
7105                 shift
7106                 cat <<-EOF
7107                 Linking shared library
7108                 ** SHARED_LIB \[$]SHARED_LIB
7109                 ** IMPORT_LIB \[$]IMPORT_LIB
7110 EOF
7111                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7112 CF_EOF
7113                 chmod +x mk_shared_lib.sh
7114                 ;;
7115         (openbsd[[2-9]].*|mirbsd*)
7116                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7117                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7118                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7119                 fi
7120                 if test "$cf_cv_enable_rpath" = yes ; then
7121                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7122                 fi
7123                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7124                 CF_SHARED_SONAME
7125                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7126                 ;;
7127         (nskJ*)
7128                 CC_SHARED_OPTS=
7129                 MK_SHARED_LIB='${LD} -Wshared -Weld=-export_all -o $[@]'
7130                 ;;
7131         (nskL*)
7132                 CC_SHARED_OPTS=
7133                 MK_SHARED_LIB='${LD} -Wshared -Wxld=-export_all -o $[@]'
7134                 ;;
7135         (nto-qnx*|openbsd*|freebsd[[12]].*)
7136                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7137                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
7138                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7139                 ;;
7140         (dragonfly*|freebsd*)
7141                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7142                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
7143                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
7144                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
7145                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7146                 fi
7147                 CF_SHARED_SONAME
7148                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7149                 ;;
7150         (netbsd*)
7151                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7152                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
7153                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
7154                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7155                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7156                         if test "$cf_cv_shlib_version" = auto; then
7157                         if test -f /usr/libexec/ld.elf_so; then
7158                                 cf_cv_shlib_version=abi
7159                         else
7160                                 cf_cv_shlib_version=rel
7161                         fi
7162                         fi
7163                         CF_SHARED_SONAME
7164                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
7165                 else
7166                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -o $[@]'
7167                 fi
7168                 ;;
7169         (osf*|mls+*)
7170                 # tested with OSF/1 V3.2 and 'cc'
7171                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
7172                 # link with shared libs).
7173                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
7174                 case $host_os in
7175                 (osf4*)
7176                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
7177                         ;;
7178                 esac
7179                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
7180                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7181                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7182                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7183                 fi
7184                 cf_cv_rm_so_locs=yes
7185                 ;;
7186         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
7187                 # tested with osr5.0.5
7188                 if test "$GCC" != yes; then
7189                         CC_SHARED_OPTS='-belf -KPIC'
7190                 fi
7191                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
7192                 if test "$cf_cv_enable_rpath" = yes ; then
7193                         # only way is to set LD_RUN_PATH but no switch for it
7194                         RUN_PATH=$libdir
7195                 fi
7196                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7197                 LINK_PROGS='LD_RUN_PATH=${libdir}'
7198                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
7199                 ;;
7200         (sunos4*)
7201                 # tested with SunOS 4.1.1 and gcc 2.7.0
7202                 if test "$GCC" != yes; then
7203                         CC_SHARED_OPTS='-KPIC'
7204                 fi
7205                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
7206                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7207                 ;;
7208         (solaris2*)
7209                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
7210                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
7211                 if test "$DFT_LWR_MODEL" = "shared" ; then
7212                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
7213                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7214                 fi
7215                 if test "$cf_cv_enable_rpath" = yes ; then
7216                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
7217                 fi
7218                 CF_SHARED_SONAME
7219                 if test "$GCC" != yes; then
7220                         cf_save_CFLAGS="$CFLAGS"
7221                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
7222                         do
7223                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
7224                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
7225                         done
7226                         CFLAGS="$cf_save_CFLAGS"
7227                         CC_SHARED_OPTS=$cf_shared_opts
7228                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
7229                 else
7230                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
7231                 fi
7232                 ;;
7233         (sysv5uw7*|unix_sv*)
7234                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
7235                 if test "$GCC" != yes; then
7236                         CC_SHARED_OPTS='-KPIC'
7237                 fi
7238                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
7239                 ;;
7240         (*)
7241                 CC_SHARED_OPTS='unknown'
7242                 MK_SHARED_LIB='echo unknown'
7243                 ;;
7244         esac
7245
7246         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
7247         case "$cf_cv_shlib_version" in
7248         (rel|abi)
7249                 case "$MK_SHARED_LIB" in
7250                 (*'-o $[@]')
7251                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
7252                         ;;
7253                 (*)
7254                         AC_MSG_WARN(ignored --with-shlib-version)
7255                         ;;
7256                 esac
7257                 ;;
7258         esac
7259
7260         if test -n "$cf_try_cflags"
7261         then
7262 cat > conftest.$ac_ext <<EOF
7263 #line __oline__ "${as_me:-configure}"
7264 #include <stdio.h>
7265 int main(int argc, char *argv[[]])
7266 {
7267         printf("hello\n");
7268         return (argv[[argc-1]] == 0) ;
7269 }
7270 EOF
7271                 cf_save_CFLAGS="$CFLAGS"
7272                 for cf_opt in $cf_try_cflags
7273                 do
7274                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
7275                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
7276                         if AC_TRY_EVAL(ac_compile); then
7277                                 AC_MSG_RESULT(yes)
7278                                 cf_save_CFLAGS="$CFLAGS"
7279                         else
7280                                 AC_MSG_RESULT(no)
7281                         fi
7282                 done
7283                 CFLAGS="$cf_save_CFLAGS"
7284         fi
7285
7286
7287         # RPATH_LIST is a colon-separated list of directories
7288         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
7289         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
7290
7291         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
7292
7293         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
7294         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7295
7296         AC_SUBST(CC_SHARED_OPTS)
7297         AC_SUBST(LD_RPATH_OPT)
7298         AC_SUBST(LD_SHARED_OPTS)
7299         AC_SUBST(MK_SHARED_LIB)
7300         AC_SUBST(RM_SHARED_OPTS)
7301
7302         AC_SUBST(LINK_PROGS)
7303         AC_SUBST(LINK_TESTS)
7304
7305         AC_SUBST(EXTRA_LDFLAGS)
7306         AC_SUBST(LOCAL_LDFLAGS)
7307         AC_SUBST(LOCAL_LDFLAGS2)
7308
7309         AC_SUBST(INSTALL_LIB)
7310         AC_SUBST(RPATH_LIST)
7311 ])dnl
7312 dnl ---------------------------------------------------------------------------
7313 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
7314 dnl ----------------
7315 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
7316 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
7317 dnl option.
7318 dnl
7319 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
7320 dnl If missing, use "rel".
7321 define([CF_SHARED_SONAME],
7322 [
7323         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
7324         if test "$cf_cv_shlib_version" = rel; then
7325                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
7326         else
7327                 cf_cv_shared_soname='`basename $[@]`'
7328         fi
7329 ])
7330 dnl ---------------------------------------------------------------------------
7331 dnl CF_SIGWINCH version: 3 updated: 2020/03/10 18:53:47
7332 dnl -----------
7333 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
7334 dnl programs need this test).
7335 dnl
7336 dnl This is really a Mac OS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
7337 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
7338 dnl winsize declaration is left alone - we may revisit this if Apple choose to
7339 dnl break that part of the interface as well.
7340 AC_DEFUN([CF_SIGWINCH],
7341 [
7342 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
7343         AC_TRY_COMPILE([
7344 #include <sys/types.h>
7345 #include <sys/signal.h>
7346 ],[int x = SIGWINCH; (void)x],
7347         [cf_cv_define_sigwinch=yes],
7348         [AC_TRY_COMPILE([
7349 #undef _XOPEN_SOURCE
7350 #undef _POSIX_SOURCE
7351 #undef _POSIX_C_SOURCE
7352 #include <sys/types.h>
7353 #include <sys/signal.h>
7354 ],[int x = SIGWINCH; (void)x],
7355         [cf_cv_define_sigwinch=maybe],
7356         [cf_cv_define_sigwinch=no])
7357 ])
7358 ])
7359
7360 if test "$cf_cv_define_sigwinch" = maybe ; then
7361 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
7362 cf_cv_fixup_sigwinch=unknown
7363 cf_sigwinch=32
7364 while test $cf_sigwinch != 1
7365 do
7366         AC_TRY_COMPILE([
7367 #undef _XOPEN_SOURCE
7368 #undef _POSIX_SOURCE
7369 #undef _POSIX_C_SOURCE
7370 #include <sys/types.h>
7371 #include <sys/signal.h>
7372 ],[
7373 #if SIGWINCH != $cf_sigwinch
7374 make an error
7375 #endif
7376 int x = SIGWINCH; (void)x],
7377         [cf_cv_fixup_sigwinch=$cf_sigwinch
7378          break])
7379
7380 cf_sigwinch=`expr $cf_sigwinch - 1`
7381 done
7382 ])
7383
7384         if test "$cf_cv_fixup_sigwinch" != unknown ; then
7385                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
7386         fi
7387 fi
7388 ])dnl
7389 dnl ---------------------------------------------------------------------------
7390 dnl CF_SIG_ATOMIC_T version: 5 updated: 2020/03/10 18:53:47
7391 dnl ---------------
7392 dnl signal handler, but there are some gcc dependencies in that recommendation.
7393 dnl Try anyway.
7394 AC_DEFUN([CF_SIG_ATOMIC_T],
7395 [
7396 AC_MSG_CHECKING(for signal global datatype)
7397 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
7398         for cf_type in \
7399                 "volatile sig_atomic_t" \
7400                 "sig_atomic_t" \
7401                 "int"
7402         do
7403         AC_TRY_COMPILE([
7404 #include <sys/types.h>
7405 #include <signal.h>
7406 #include <stdio.h>
7407
7408 extern $cf_type x;
7409 $cf_type x;
7410 static void handler(int sig)
7411 {
7412         (void)sig;
7413         x = 5;
7414 }],
7415                 [signal(SIGINT, handler);
7416                  x = 1],
7417                 [cf_cv_sig_atomic_t=$cf_type],
7418                 [cf_cv_sig_atomic_t=no])
7419                 test "$cf_cv_sig_atomic_t" != no && break
7420         done
7421         ])
7422 AC_MSG_RESULT($cf_cv_sig_atomic_t)
7423 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
7424 ])dnl
7425 dnl ---------------------------------------------------------------------------
7426 dnl CF_SIZECHANGE version: 16 updated: 2020/03/19 20:46:13
7427 dnl -------------
7428 dnl Check for definitions & structures needed for window size-changing
7429 dnl
7430 dnl https://stackoverflow.com/questions/18878141/difference-between-structures-ttysize-and-winsize/50769952#50769952
7431 AC_DEFUN([CF_SIZECHANGE],
7432 [
7433 AC_REQUIRE([CF_STRUCT_TERMIOS])
7434 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
7435         cf_cv_sizechange=unknown
7436         cf_save_CPPFLAGS="$CPPFLAGS"
7437
7438 for cf_opts in "" "NEED_PTEM_H"
7439 do
7440
7441         CPPFLAGS="$cf_save_CPPFLAGS"
7442         if test -n "$cf_opts"
7443         then
7444                 CF_APPEND_TEXT(CPPFLAGS,-D$cf_opts)
7445         fi
7446         AC_TRY_COMPILE([#include <sys/types.h>
7447 #ifdef HAVE_TERMIOS_H
7448 #include <termios.h>
7449 #else
7450 #ifdef HAVE_TERMIO_H
7451 #include <termio.h>
7452 #endif
7453 #endif
7454
7455 #ifdef NEED_PTEM_H
7456 /* This is a workaround for SCO:  they neglected to define struct winsize in
7457  * termios.h -- it's only in termio.h and ptem.h
7458  */
7459 #include <sys/stream.h>
7460 #include <sys/ptem.h>
7461 #endif
7462
7463 #ifdef HAVE_SYS_IOCTL_H
7464 #include <sys/ioctl.h>
7465 #endif
7466 ],[
7467 #ifdef TIOCGSIZE
7468         struct ttysize win;     /* SunOS 3.0... */
7469         int y = win.ts_lines = 2;
7470         int x = win.ts_cols = 1;
7471         (void)y;
7472         (void)x;
7473 #else
7474 #ifdef TIOCGWINSZ
7475         struct winsize win;     /* everything else */
7476         int y = win.ws_row = 2;
7477         int x = win.ws_col = 1;
7478         (void)y;
7479         (void)x;
7480 #else
7481         no TIOCGSIZE or TIOCGWINSZ
7482 #endif /* TIOCGWINSZ */
7483 #endif /* TIOCGSIZE */
7484         ],
7485         [cf_cv_sizechange=yes],
7486         [cf_cv_sizechange=no])
7487
7488         CPPFLAGS="$cf_save_CPPFLAGS"
7489         if test "$cf_cv_sizechange" = yes ; then
7490                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
7491                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
7492                 break
7493         fi
7494 done
7495 ])
7496 if test "$cf_cv_sizechange" != no ; then
7497         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechange declarations are provided])
7498         case $cf_cv_sizechange in
7499         (NEED*)
7500                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
7501                 ;;
7502         esac
7503 fi
7504 ])dnl
7505 dnl ---------------------------------------------------------------------------
7506 dnl CF_SRC_MODULES version: 32 updated: 2020/03/07 20:05:14
7507 dnl --------------
7508 dnl For each parameter, test if the source-directory exists, and if it contains
7509 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
7510 dnl use in CF_LIB_RULES.
7511 dnl
7512 dnl This uses the configured value to make the lists SRC_SUBDIRS and
7513 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
7514 AC_DEFUN([CF_SRC_MODULES],
7515 [
7516 AC_REQUIRE([CF_CHECK_GNAT_VERSION])
7517 AC_MSG_CHECKING(for src modules)
7518
7519 # dependencies and linker-arguments for test-programs
7520 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
7521 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
7522 if test "$DFT_LWR_MODEL" = "libtool"; then
7523         TEST_ARGS="${TEST_DEPS}"
7524         TEST_ARG2="${TEST_DEP2}"
7525 else
7526         TEST_ARGS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
7527         TEST_ARG2="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARG2"
7528 fi
7529
7530 PC_MODULES_TO_MAKE="ncurses${USE_ARG_SUFFIX}"
7531 cf_cv_src_modules=
7532 for cf_dir in $1
7533 do
7534         if test -f $srcdir/$cf_dir/modules; then
7535
7536                 # We may/may not have tack in the distribution, though the
7537                 # makefile is.
7538                 if test $cf_dir = tack ; then
7539                         if test "x$cf_with_tack" != "xyes"; then
7540                                 continue
7541                         fi
7542                 fi
7543
7544                 if test -z "$cf_cv_src_modules"; then
7545                         cf_cv_src_modules=$cf_dir
7546                 else
7547                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
7548                 fi
7549
7550                 # Make the ncurses_cfg.h file record the library interface files as
7551                 # well.  These are header files that are the same name as their
7552                 # directory.  Ncurses is the only library that does not follow
7553                 # that pattern.
7554                 if test $cf_dir = tack ; then
7555                         continue
7556                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
7557                         CF_UPPER(cf_have_include,$cf_dir)
7558                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
7559                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
7560                         CF_MAP_LIB_BASENAME(TEST_ROOT,$cf_dir)
7561                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEPS"
7562                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEP2"
7563                         if test "$DFT_LWR_MODEL" = "libtool"; then
7564                                 TEST_ARGS="${TEST_DEPS}"
7565                                 TEST_ARG2="${TEST_DEP2}"
7566                         else
7567                                 TEST_ARGS="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARGS"
7568                                 TEST_ARG2="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARG2"
7569                         fi
7570                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${USE_ARG_SUFFIX}"
7571                 fi
7572         fi
7573 done
7574 AC_MSG_RESULT($cf_cv_src_modules)
7575
7576 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
7577 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
7578
7579 AC_SUBST(TEST_ARGS)
7580 AC_SUBST(TEST_DEPS)
7581
7582 AC_SUBST(TEST_ARG2)
7583 AC_SUBST(TEST_DEP2)
7584
7585 SRC_SUBDIRS=
7586 if test "x$cf_with_manpages" != xno ; then
7587         SRC_SUBDIRS="$SRC_SUBDIRS man"
7588 fi
7589 SRC_SUBDIRS="$SRC_SUBDIRS include"
7590 for cf_dir in $cf_cv_src_modules
7591 do
7592         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
7593 done
7594 if test "x$cf_with_tests" != "xno" ; then
7595         SRC_SUBDIRS="$SRC_SUBDIRS test"
7596 fi
7597 # always make this, to install the ncurses-config script
7598 SRC_SUBDIRS="$SRC_SUBDIRS misc"
7599 if test "$cf_with_cxx_binding" != no; then
7600         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${USE_ARG_SUFFIX}"
7601         SRC_SUBDIRS="$SRC_SUBDIRS c++"
7602 fi
7603
7604 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
7605 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
7606
7607 AC_SUBST(PC_MODULES_TO_MAKE)
7608
7609 ADA_SUBDIRS=
7610 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
7611         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
7612         ADA_SUBDIRS="gen src"
7613         if test "x$cf_with_tests" != "xno" ; then
7614                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
7615         fi
7616 fi
7617
7618 SUB_MAKEFILES=
7619 for cf_dir in $SRC_SUBDIRS
7620 do
7621         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
7622 done
7623
7624 if test -n "$ADA_SUBDIRS"; then
7625         for cf_dir in $ADA_SUBDIRS
7626         do
7627                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
7628         done
7629         AC_SUBST(ADA_SUBDIRS)
7630 fi
7631 ])dnl
7632 dnl ---------------------------------------------------------------------------
7633 dnl CF_STDCPP_LIBRARY version: 11 updated: 2015/10/17 19:03:33
7634 dnl -----------------
7635 dnl Check for -lstdc++, which is GNU's standard C++ library.
7636 dnl If $CXXLIBS is set, add that to the libraries used for test-linking.
7637 dnl If -lstdc++ was not already added to $LIBS or $CXXLIBS, and is needed,
7638 dnl add it to $CXXLIBS.
7639 AC_DEFUN([CF_STDCPP_LIBRARY],
7640 [
7641 if test -n "$GXX" ; then
7642
7643         cf_save="$LIBS"
7644         LIBS="$LIBS $CXXLIBS"
7645         AC_MSG_CHECKING(if we already have C++ library)
7646         AC_TRY_LINK([
7647                         #include <iostream>],[
7648                         std::cout << "Hello World!" << std::endl;],
7649                 [cf_have_libstdcpp=yes],
7650                 [cf_have_libstdcpp=no])
7651         AC_MSG_RESULT($cf_have_libstdcpp)
7652         LIBS="$cf_save"
7653
7654         if test $cf_have_libstdcpp != yes
7655         then
7656                 case $cf_cv_system_name in
7657                 (os2*)
7658                         if test -z "`g++ -dM -E - < /dev/null | grep __KLIBC__`"; then
7659                                 cf_stdcpp_libname=stdcpp
7660                         else
7661                                 cf_stdcpp_libname=stdc++
7662                         fi
7663                         ;;
7664                 (*)
7665                         cf_stdcpp_libname=stdc++
7666                         ;;
7667                 esac
7668
7669                 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
7670                         cf_save="$LIBS"
7671                         LIBS="$LIBS $CXXLIBS"
7672                         CF_ADD_LIB($cf_stdcpp_libname)
7673                 AC_TRY_LINK([
7674                                 #include <iostream>],[
7675                                 std::cout << "Hello World!" << std::endl;],
7676                         [cf_cv_libstdcpp=yes],
7677                         [cf_cv_libstdcpp=no])
7678                         LIBS="$cf_save"
7679                 ])
7680                 test "$cf_cv_libstdcpp" = yes && { CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS) }
7681         fi
7682 fi
7683 ])dnl
7684 dnl ---------------------------------------------------------------------------
7685 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
7686 dnl --------------
7687 dnl     Remove "-g" option from the compiler options
7688 AC_DEFUN([CF_STRIP_G_OPT],
7689 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
7690 dnl ---------------------------------------------------------------------------
7691 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
7692 dnl -------------------
7693 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
7694 dnl do this if we've found the sigaction function.
7695 AC_DEFUN([CF_STRUCT_SIGACTION],[
7696 AC_REQUIRE([CF_XOPEN_SOURCE])
7697
7698 if test "$ac_cv_func_sigaction" = yes; then
7699 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
7700 AC_TRY_COMPILE([
7701 #include <sys/types.h>
7702 #include <signal.h>],
7703         [struct sigaction act],
7704         [sigact_bad=no],
7705         [
7706 AC_TRY_COMPILE([
7707 #define _POSIX_SOURCE
7708 #include <sys/types.h>
7709 #include <signal.h>],
7710         [struct sigaction act],
7711         [sigact_bad=yes
7712          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
7713          [sigact_bad=unknown])])
7714 AC_MSG_RESULT($sigact_bad)
7715 fi
7716 ])dnl
7717 dnl ---------------------------------------------------------------------------
7718 dnl CF_STRUCT_TERMIOS version: 11 updated: 2020/03/19 20:46:13
7719 dnl -----------------
7720 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
7721 AC_DEFUN([CF_STRUCT_TERMIOS],[
7722 AC_REQUIRE([CF_XOPEN_SOURCE])
7723
7724 AC_CHECK_HEADERS( \
7725 termio.h \
7726 termios.h \
7727 unistd.h \
7728 sys/ioctl.h \
7729 sys/termio.h \
7730 )
7731
7732 if test "$ac_cv_header_termios_h" = yes ; then
7733         case "$CFLAGS $CPPFLAGS" in
7734         (*-D_POSIX_SOURCE*)
7735                 termios_bad=dunno ;;
7736         (*)     termios_bad=maybe ;;
7737         esac
7738         if test "$termios_bad" = maybe ; then
7739         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
7740         AC_TRY_COMPILE([#include <termios.h>],
7741                 [struct termios foo; int x = foo.c_iflag = 1; (void)x],
7742                 termios_bad=no, [
7743                 AC_TRY_COMPILE([
7744 #define _POSIX_SOURCE
7745 #include <termios.h>],
7746                         [struct termios foo; int x = foo.c_iflag = 2; (void)x],
7747                         termios_bad=unknown,
7748                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
7749                         ])
7750         AC_MSG_RESULT($termios_bad)
7751         fi
7752 fi
7753 ])dnl
7754 dnl ---------------------------------------------------------------------------
7755 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
7756 dnl --------------
7757 dnl Construct a search-list for a nonstandard header/lib-file
7758 dnl     $1 = the variable to return as result
7759 dnl     $2 = the package name
7760 dnl     $3 = the subdirectory, e.g., bin, include or lib
7761 AC_DEFUN([CF_SUBDIR_PATH],
7762 [
7763 $1=
7764
7765 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
7766
7767 for cf_subdir_prefix in \
7768         /usr \
7769         /usr/local \
7770         /usr/pkg \
7771         /opt \
7772         /opt/local \
7773         [$]HOME
7774 do
7775         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
7776 done
7777 ])dnl
7778 dnl ---------------------------------------------------------------------------
7779 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
7780 dnl -----------
7781 dnl     Shorthand macro for substituting things that the user may override
7782 dnl     with an environment variable.
7783 dnl
7784 dnl     $1 = condition to pass to "test"
7785 dnl     $2 = environment variable
7786 dnl     $3 = value if the test succeeds
7787 dnl     $4 = value if the test fails
7788 AC_DEFUN([CF_SUBST_IF],
7789 [
7790 if test $1 ; then
7791         $2=$3
7792 ifelse($4,,,[else
7793         $2=$4])
7794 fi
7795 AC_SUBST($2)
7796 ])dnl
7797 dnl ---------------------------------------------------------------------------
7798 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
7799 dnl ------------------------
7800 dnl Get the version-number for use in shared-library naming, etc.
7801 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
7802 [
7803 AC_REQUIRE([CF_PROG_EGREP])
7804 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
7805 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
7806 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
7807 cf_cv_abi_version=${NCURSES_MAJOR}
7808 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
7809 dnl Show the computed version, for logging
7810 cf_cv_timestamp=`date`
7811 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
7812 dnl We need these values in the generated headers
7813 AC_SUBST(NCURSES_MAJOR)
7814 AC_SUBST(NCURSES_MINOR)
7815 AC_SUBST(NCURSES_PATCH)
7816 dnl We need these values in the generated makefiles
7817 AC_SUBST(cf_cv_rel_version)
7818 AC_SUBST(cf_cv_abi_version)
7819 AC_SUBST(cf_cv_builtin_bool)
7820 AC_SUBST(cf_cv_header_stdbool_h)
7821 AC_SUBST(cf_cv_type_of_bool)dnl
7822 ])dnl
7823 dnl ---------------------------------------------------------------------------
7824 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
7825 dnl ------------------
7826 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
7827 dnl older SCO configurations.
7828 AC_DEFUN([CF_SYS_TIME_SELECT],
7829 [
7830 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
7831 AC_CACHE_VAL(cf_cv_sys_time_select,[
7832 AC_TRY_COMPILE([
7833 #include <sys/types.h>
7834 #ifdef HAVE_SYS_TIME_H
7835 #include <sys/time.h>
7836 #endif
7837 #ifdef HAVE_SYS_SELECT_H
7838 #include <sys/select.h>
7839 #endif
7840 ],[],[cf_cv_sys_time_select=yes],
7841          [cf_cv_sys_time_select=no])
7842          ])
7843 AC_MSG_RESULT($cf_cv_sys_time_select)
7844 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
7845 ])dnl
7846 dnl ---------------------------------------------------------------------------
7847 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
7848 dnl ---------------
7849 dnl Define a top_builddir symbol, for applications that need an absolute path.
7850 AC_DEFUN([CF_TOP_BUILDDIR],
7851 [
7852 top_builddir=ifelse($1,,`pwd`,$1)
7853 AC_SUBST(top_builddir)
7854 ])dnl
7855 dnl ---------------------------------------------------------------------------
7856 dnl CF_TRY_PKG_CONFIG version: 5 updated: 2013/07/06 21:27:06
7857 dnl -----------------
7858 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
7859 dnl available in that form.
7860 dnl
7861 dnl $1 = package name
7862 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
7863 dnl $3 = logic to use if pkg-config does not have the package
7864 AC_DEFUN([CF_TRY_PKG_CONFIG],[
7865 AC_REQUIRE([CF_PKG_CONFIG])
7866
7867 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists $1; then
7868         CF_VERBOSE(found package $1)
7869         cf_pkgconfig_incs="`$PKG_CONFIG --cflags $1 2>/dev/null`"
7870         cf_pkgconfig_libs="`$PKG_CONFIG --libs   $1 2>/dev/null`"
7871         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
7872         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
7873         CF_ADD_CFLAGS($cf_pkgconfig_incs)
7874         CF_ADD_LIBS($cf_pkgconfig_libs)
7875         ifelse([$2],,:,[$2])
7876 else
7877         cf_pkgconfig_incs=
7878         cf_pkgconfig_libs=
7879         ifelse([$3],,:,[$3])
7880 fi
7881 ])
7882 dnl ---------------------------------------------------------------------------
7883 dnl CF_TRY_XOPEN_SOURCE version: 2 updated: 2018/06/20 20:23:13
7884 dnl -------------------
7885 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
7886 dnl can define it successfully.
7887 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
7888 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
7889         AC_TRY_COMPILE([
7890 #include <stdlib.h>
7891 #include <string.h>
7892 #include <sys/types.h>
7893 ],[
7894 #ifndef _XOPEN_SOURCE
7895 make an error
7896 #endif],
7897         [cf_cv_xopen_source=no],
7898         [cf_save="$CPPFLAGS"
7899          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
7900          AC_TRY_COMPILE([
7901 #include <stdlib.h>
7902 #include <string.h>
7903 #include <sys/types.h>
7904 ],[
7905 #ifdef _XOPEN_SOURCE
7906 make an error
7907 #endif],
7908         [cf_cv_xopen_source=no],
7909         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
7910         CPPFLAGS="$cf_save"
7911         ])
7912 ])
7913
7914 if test "$cf_cv_xopen_source" != no ; then
7915         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
7916         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
7917         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
7918         CF_ADD_CFLAGS($cf_temp_xopen_source)
7919 fi
7920 ])
7921 dnl ---------------------------------------------------------------------------
7922 dnl CF_TYPEOF_CHTYPE version: 10 updated: 2017/01/21 11:06:25
7923 dnl ----------------
7924 dnl Determine the type we should use for chtype (and attr_t, which is treated
7925 dnl as the same thing).  We want around 32 bits, so on most machines want a
7926 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
7927 dnl wide characters, we have to have a type compatible with that, as well.
7928 AC_DEFUN([CF_TYPEOF_CHTYPE],
7929 [
7930 AC_MSG_CHECKING([for type of chtype])
7931 AC_CACHE_VAL(cf_cv_typeof_chtype,[
7932                 AC_TRY_RUN([
7933 #define WANT_BITS 31
7934 #include <stdio.h>
7935 int main(void)
7936 {
7937         FILE *fp = fopen("cf_test.out", "w");
7938         if (fp != 0) {
7939                 char *result = "long";
7940                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
7941                         int n;
7942                         unsigned int x, y;
7943                         for (n = 0; n < WANT_BITS; n++) {
7944                                 x = (1 << n);
7945                                 y = (x >> n);
7946                                 if (y != 1 || x == 0) {
7947                                         x = 0;
7948                                         break;
7949                                 }
7950                         }
7951                         /*
7952                          * If x is nonzero, an int is big enough for the bits
7953                          * that we want.
7954                          */
7955                         result = (x != 0) ? "int" : "long";
7956                 }
7957                 fputs(result, fp);
7958                 fclose(fp);
7959         }
7960         ${cf_cv_main_return:-return}(0);
7961 }
7962                 ],
7963                 [cf_cv_typeof_chtype=`cat cf_test.out`],
7964                 [cf_cv_typeof_chtype=long],
7965                 [cf_cv_typeof_chtype=long])
7966                 rm -f cf_test.out
7967         ])
7968 AC_MSG_RESULT($cf_cv_typeof_chtype)
7969
7970 AC_SUBST(cf_cv_typeof_chtype)
7971 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
7972 ])dnl
7973 dnl ---------------------------------------------------------------------------
7974 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
7975 dnl -----------------
7976 dnl
7977 AC_DEFUN([CF_TYPE_SIGACTION],
7978 [
7979 AC_MSG_CHECKING([for type sigaction_t])
7980 AC_CACHE_VAL(cf_cv_type_sigaction,[
7981         AC_TRY_COMPILE([
7982 #include <signal.h>],
7983                 [sigaction_t x],
7984                 [cf_cv_type_sigaction=yes],
7985                 [cf_cv_type_sigaction=no])])
7986 AC_MSG_RESULT($cf_cv_type_sigaction)
7987 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
7988 ])dnl
7989 dnl ---------------------------------------------------------------------------
7990 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
7991 dnl --------------------
7992 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
7993 dnl won't, but they're still there.
7994 AC_DEFUN([CF_UNSIGNED_LITERALS],
7995 [
7996 AC_MSG_CHECKING([if unsigned literals are legal])
7997 AC_CACHE_VAL(cf_cv_unsigned_literals,[
7998         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
7999                 [cf_cv_unsigned_literals=yes],
8000                 [cf_cv_unsigned_literals=no])
8001         ])
8002 AC_MSG_RESULT($cf_cv_unsigned_literals)
8003 ])dnl
8004 dnl ---------------------------------------------------------------------------
8005 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
8006 dnl --------
8007 dnl Make an uppercase version of a variable
8008 dnl $1=uppercase($2)
8009 AC_DEFUN([CF_UPPER],
8010 [
8011 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
8012 ])dnl
8013 dnl ---------------------------------------------------------------------------
8014 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
8015 dnl -----------
8016 dnl Check for multibyte support, and if not found, utf8 compatibility library
8017 AC_DEFUN([CF_UTF8_LIB],
8018 [
8019 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
8020         cf_save_LIBS="$LIBS"
8021         AC_TRY_LINK([
8022 #include <stdlib.h>],[putwc(0,0);],
8023         [cf_cv_utf8_lib=yes],
8024         [CF_FIND_LINKAGE([
8025 #include <libutf8.h>],[putwc(0,0);],utf8,
8026                 [cf_cv_utf8_lib=add-on],
8027                 [cf_cv_utf8_lib=no])
8028 ])])
8029
8030 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
8031 # ncurses/ncursesw:
8032 if test "$cf_cv_utf8_lib" = "add-on" ; then
8033         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
8034         CF_ADD_INCDIR($cf_cv_header_path_utf8)
8035         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
8036         CF_ADD_LIBS($cf_cv_library_file_utf8)
8037 fi
8038 ])dnl
8039 dnl ---------------------------------------------------------------------------
8040 dnl CF_VA_COPY version: 6 updated: 2018/12/04 18:14:25
8041 dnl ----------
8042 dnl check for va_copy, part of stdarg.h starting with ISO C 1999.
8043 dnl Also, workaround for glibc's __va_copy, by checking for both.
8044 dnl Finally, try to accommodate pre-ISO C 1999 headers.
8045 AC_DEFUN([CF_VA_COPY],[
8046 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
8047 AC_TRY_LINK([
8048 #include <stdarg.h>
8049 ],[
8050         static va_list dst;
8051         static va_list src;
8052         va_copy(dst, src)],
8053         cf_cv_have_va_copy=yes,
8054         cf_cv_have_va_copy=no)])
8055
8056 if test "$cf_cv_have_va_copy" = yes;
8057 then
8058         AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
8059 else # !cf_cv_have_va_copy
8060
8061 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
8062 AC_TRY_LINK([
8063 #include <stdarg.h>
8064 ],[
8065         static va_list dst;
8066         static va_list src;
8067         __va_copy(dst, src)],
8068         cf_cv_have___va_copy=yes,
8069         cf_cv_have___va_copy=no)])
8070
8071 if test "$cf_cv_have___va_copy" = yes
8072 then
8073         AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
8074 else # !cf_cv_have___va_copy
8075
8076 AC_CACHE_CHECK(for __builtin_va_copy, cf_cv_have___builtin_va_copy,[
8077 AC_TRY_LINK([
8078 #include <stdarg.h>
8079 ],[
8080         static va_list dst;
8081         static va_list src;
8082         __builtin_va_copy(dst, src)],
8083         cf_cv_have___builtin_va_copy=yes,
8084         cf_cv_have___builtin_va_copy=no)])
8085
8086 test "$cf_cv_have___builtin_va_copy" = yes &&
8087         AC_DEFINE(HAVE___BUILTIN_VA_COPY,1,[Define to 1 if we have __builtin_va_copy])
8088
8089 fi # cf_cv_have___va_copy
8090
8091 fi # cf_cv_have_va_copy
8092
8093 case "${cf_cv_have_va_copy}${cf_cv_have___va_copy}${cf_cv_have___builtin_va_copy}" in
8094 (*yes*)
8095         ;;
8096
8097 (*)
8098         AC_CACHE_CHECK(if we can simply copy va_list, cf_cv_pointer_va_list,[
8099 AC_TRY_LINK([
8100 #include <stdarg.h>
8101 ],[
8102         va_list dst;
8103         va_list src;
8104         dst = src],
8105         cf_cv_pointer_va_list=yes,
8106         cf_cv_pointer_va_list=no)])
8107
8108         if test "$cf_cv_pointer_va_list" = no
8109         then
8110                 AC_CACHE_CHECK(if we can copy va_list indirectly, cf_cv_array_va_list,[
8111 AC_TRY_LINK([
8112 #include <stdarg.h>
8113 ],[
8114         va_list dst;
8115         va_list src;
8116         *dst = *src],
8117                         cf_cv_array_va_list=yes,
8118                         cf_cv_array_va_list=no)])
8119                 test "$cf_cv_array_va_list" = yes && AC_DEFINE(ARRAY_VA_LIST,1,[Define to 1 if we can copy va_list indirectly])
8120         fi
8121         ;;
8122 esac
8123 ])
8124 dnl ---------------------------------------------------------------------------
8125 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
8126 dnl ----------
8127 dnl Use AC_VERBOSE w/o the warnings
8128 AC_DEFUN([CF_VERBOSE],
8129 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
8130 CF_MSG_LOG([$1])
8131 ])dnl
8132 dnl ---------------------------------------------------------------------------
8133 dnl CF_VERSION_INFO version: 7 updated: 2015/04/17 21:13:04
8134 dnl ---------------
8135 dnl Define several useful symbols derived from the VERSION file.  A separate
8136 dnl file is preferred to embedding the version numbers in various scripts.
8137 dnl (automake is a textbook-example of why the latter is a bad idea, but there
8138 dnl are others).
8139 dnl
8140 dnl The file contents are:
8141 dnl     libtool-version release-version patch-version
8142 dnl or
8143 dnl     release-version
8144 dnl where
8145 dnl     libtool-version (see ?) consists of 3 integers separated by '.'
8146 dnl     release-version consists of a major version and minor version
8147 dnl             separated by '.', optionally followed by a patch-version
8148 dnl             separated by '-'.  The minor version need not be an
8149 dnl             integer (but it is preferred).
8150 dnl     patch-version is an integer in the form yyyymmdd, so ifdef's and
8151 dnl             scripts can easily compare versions.
8152 dnl
8153 dnl If libtool is used, the first form is required, since CF_WITH_LIBTOOL
8154 dnl simply extracts the first field using 'cut -f1'.
8155 dnl
8156 dnl Optional parameters:
8157 dnl $1 = internal name for package
8158 dnl $2 = external name for package
8159 AC_DEFUN([CF_VERSION_INFO],
8160 [
8161 if test -f $srcdir/VERSION ; then
8162         AC_MSG_CHECKING(for package version)
8163
8164         # if there are not enough fields, cut returns the last one...
8165         cf_field1=`sed -e '2,$d' $srcdir/VERSION|cut -f1`
8166         cf_field2=`sed -e '2,$d' $srcdir/VERSION|cut -f2`
8167         cf_field3=`sed -e '2,$d' $srcdir/VERSION|cut -f3`
8168
8169         # this is how CF_BUNDLED_INTL uses $VERSION:
8170         VERSION="$cf_field1"
8171
8172         VERSION_MAJOR=`echo "$cf_field2" | sed -e 's/\..*//'`
8173         test -z "$VERSION_MAJOR" && AC_MSG_ERROR(missing major-version)
8174
8175         VERSION_MINOR=`echo "$cf_field2" | sed -e 's/^[[^.]]*\.//' -e 's/-.*//'`
8176         test -z "$VERSION_MINOR" && AC_MSG_ERROR(missing minor-version)
8177
8178         AC_MSG_RESULT(${VERSION_MAJOR}.${VERSION_MINOR})
8179
8180         AC_MSG_CHECKING(for package patch date)
8181         VERSION_PATCH=`echo "$cf_field3" | sed -e 's/^[[^-]]*-//'`
8182         case .$VERSION_PATCH in
8183         (.)
8184                 AC_MSG_ERROR(missing patch-date $VERSION_PATCH)
8185                 ;;
8186         (.[[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]])
8187                 ;;
8188         (*)
8189                 AC_MSG_ERROR(illegal patch-date $VERSION_PATCH)
8190                 ;;
8191         esac
8192         AC_MSG_RESULT($VERSION_PATCH)
8193 else
8194         AC_MSG_ERROR(did not find $srcdir/VERSION)
8195 fi
8196
8197 # show the actual data that we have for versions:
8198 CF_VERBOSE(ABI VERSION $VERSION)
8199 CF_VERBOSE(VERSION_MAJOR $VERSION_MAJOR)
8200 CF_VERBOSE(VERSION_MINOR $VERSION_MINOR)
8201 CF_VERBOSE(VERSION_PATCH $VERSION_PATCH)
8202
8203 AC_SUBST(VERSION)
8204 AC_SUBST(VERSION_MAJOR)
8205 AC_SUBST(VERSION_MINOR)
8206 AC_SUBST(VERSION_PATCH)
8207
8208 dnl if a package name is given, define its corresponding version info.  We
8209 dnl need the package name to ensure that the defined symbols are unique.
8210 ifelse($1,,,[
8211         cf_PACKAGE=$1
8212         PACKAGE=ifelse($2,,$1,$2)
8213         AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",[Define to the package-name])
8214         AC_SUBST(PACKAGE)
8215         CF_UPPER(cf_PACKAGE,$cf_PACKAGE)
8216         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_VERSION,"${VERSION_MAJOR}.${VERSION_MINOR}")
8217         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_PATCHDATE,${VERSION_PATCH})
8218 ])
8219 ])dnl
8220 dnl ---------------------------------------------------------------------------
8221 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
8222 dnl -------------
8223 dnl Check if type wide-character type $1 is declared, and if so, which header
8224 dnl file is needed.  The second parameter is used to set a shell variable when
8225 dnl the type is not found.  The first parameter sets a shell variable for the
8226 dnl opposite sense.
8227 AC_DEFUN([CF_WCHAR_TYPE],
8228 [
8229 # This is needed on Tru64 5.0 to declare $1
8230 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
8231 AC_TRY_COMPILE([
8232 #include <stdlib.h>
8233 #include <stdarg.h>
8234 #include <stdio.h>
8235 #ifdef HAVE_LIBUTF8_H
8236 #include <libutf8.h>
8237 #endif],
8238         [$1 state],
8239         [cf_cv_$1=no],
8240         [AC_TRY_COMPILE([
8241 #include <stdlib.h>
8242 #include <stdarg.h>
8243 #include <stdio.h>
8244 #include <wchar.h>
8245 #ifdef HAVE_LIBUTF8_H
8246 #include <libutf8.h>
8247 #endif],
8248         [$1 value],
8249         [cf_cv_$1=yes],
8250         [cf_cv_$1=unknown])])])
8251
8252 if test "$cf_cv_$1" = yes ; then
8253         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
8254         NEED_WCHAR_H=1
8255 fi
8256
8257 ifelse([$2],,,[
8258 # if we do not find $1 in either place, use substitution to provide a fallback.
8259 if test "$cf_cv_$1" = unknown ; then
8260         $2=1
8261 fi
8262 ])
8263 ifelse($3,,,[
8264 # if we find $1 in either place, use substitution to provide a fallback.
8265 if test "$cf_cv_$1" != unknown ; then
8266         $3=1
8267 fi
8268 ])
8269 ])dnl
8270 dnl ---------------------------------------------------------------------------
8271 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
8272 dnl ---------------
8273 dnl Check for compiler-support for weak symbols.
8274 dnl This works with "recent" gcc.
8275 AC_DEFUN([CF_WEAK_SYMBOLS],[
8276 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
8277
8278 AC_TRY_COMPILE([
8279 #include <stdio.h>],
8280 [
8281 #if defined(__GNUC__)
8282 #  if defined __USE_ISOC99
8283 #    define _cat_pragma(exp)    _Pragma(#exp)
8284 #    define _weak_pragma(exp)   _cat_pragma(weak name)
8285 #  else
8286 #    define _weak_pragma(exp)
8287 #  endif
8288 #  define _declare(name)        __extension__ extern __typeof__(name) name
8289 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
8290 #endif
8291
8292 weak_symbol(fopen);
8293 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
8294 ])
8295 ])dnl
8296 dnl ---------------------------------------------------------------------------
8297 dnl CF_WITH_ABI_VERSION version: 3 updated: 2015/06/06 16:10:11
8298 dnl -------------------
8299 dnl Allow library's ABI to be overridden.  Generally this happens when a
8300 dnl packager has incremented the ABI past that used in the original package,
8301 dnl and wishes to keep doing this.
8302 dnl
8303 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
8304 dnl symbol.
8305 AC_DEFUN([CF_WITH_ABI_VERSION],[
8306 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
8307 AC_ARG_WITH(abi-version,
8308 [  --with-abi-version=XXX  override derived ABI version],[
8309         if test "x$cf_cv_abi_version" != "x$withval"
8310         then
8311                 AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
8312                 case $cf_cv_rel_version in
8313                 (5.*)
8314                         cf_cv_rel_version=$withval.0
8315                         ;;
8316                 (6.*)
8317                         cf_cv_rel_version=$withval.9    # FIXME: should be 10 as of 6.0 release
8318                         ;;
8319                 esac
8320         fi
8321         cf_cv_abi_version=$withval])
8322         CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
8323 ifelse($1,,,[
8324 $1_ABI=$cf_cv_abi_version
8325 ])
8326 ])dnl
8327 dnl ---------------------------------------------------------------------------
8328 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
8329 dnl --------------------
8330 dnl Command-line option to specify the Ada95 compiler.
8331 AC_DEFUN([CF_WITH_ADA_COMPILER],[
8332 AC_MSG_CHECKING(for ada-compiler)
8333 AC_ARG_WITH(ada-compiler,
8334         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
8335         [cf_ada_compiler=$withval],
8336         [cf_ada_compiler=gnatmake])
8337 AC_SUBST(cf_ada_compiler)
8338 AC_MSG_RESULT($cf_ada_compiler)
8339 ])dnl
8340 dnl ---------------------------------------------------------------------------
8341 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
8342 dnl -------------------
8343 dnl Command-line option to specify where Ada includes will install.
8344 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
8345 AC_MSG_CHECKING(for ada-include)
8346 CF_WITH_PATH(ada-include,
8347    [  --with-ada-include=DIR  Ada includes are in DIR],
8348    ADA_INCLUDE,
8349    PREFIX/share/ada/adainclude,
8350    [$]prefix/share/ada/adainclude)
8351 AC_SUBST(ADA_INCLUDE)
8352 AC_MSG_RESULT($ADA_INCLUDE)
8353 ])dnl
8354 dnl ---------------------------------------------------------------------------
8355 dnl CF_WITH_ADA_LIBNAME version: 1 updated: 2019/09/07 18:59:41
8356 dnl -------------------
8357 dnl CF_WITH_ADA_LIBNAME
8358 dnl -------------------
8359 dnl Command-line option to specify how to name the resulting Ada library.
8360 dnl $1 = default value
8361 AC_DEFUN([CF_WITH_ADA_LIBNAME],[
8362 AC_MSG_CHECKING(for ada-libname)
8363 AC_ARG_WITH(ada-libname,
8364    [  --with-ada-libname=XXX  override default Ada library-name],
8365    ADA_LIBNAME=[$]withval,
8366    ADA_LIBNAME=$1)
8367 case "x$ADA_LIBNAME" in
8368 (x|xyes|xno)
8369         ADA_LIBNAME=$1
8370         ;;
8371 esac
8372 AC_SUBST(ADA_LIBNAME)
8373 AC_MSG_RESULT($ADA_LIBNAME)
8374 ])dnl
8375 dnl ---------------------------------------------------------------------------
8376 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
8377 dnl -------------------
8378 dnl Command-line option to specify where Ada objects will install.
8379 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
8380 AC_MSG_CHECKING(for ada-objects)
8381 CF_WITH_PATH(ada-objects,
8382    [  --with-ada-objects=DIR  Ada objects are in DIR],
8383    ADA_OBJECTS,
8384    PREFIX/lib/ada/adalib,
8385    [$]prefix/lib/ada/adalib)
8386 AC_SUBST(ADA_OBJECTS)
8387 AC_MSG_RESULT($ADA_OBJECTS)
8388 ])dnl
8389 dnl ---------------------------------------------------------------------------
8390 dnl CF_WITH_ADA_SHAREDLIB version: 5 updated: 2018/07/21 19:10:35
8391 dnl ---------------------
8392 dnl Command-line option to specify if an Ada95 shared-library should be built,
8393 dnl and optionally what its soname should be.
8394 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
8395 AC_REQUIRE([CF_GNAT_PROJECTS])
8396 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
8397 AC_ARG_WITH(ada-sharedlib,
8398         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
8399         [with_ada_sharedlib=$withval],
8400         [with_ada_sharedlib=no])
8401 AC_MSG_RESULT($with_ada_sharedlib)
8402
8403 if test "x$with_ada_sharedlib" != xno
8404 then
8405         if test "x$cf_gnat_projects" != xyes
8406         then
8407                 AC_MSG_WARN(disabling shared-library since GNAT projects are not supported)
8408                 with_ada_sharedlib=no
8409         fi
8410 fi
8411
8412 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
8413 MAKE_ADA_SHAREDLIB="#"
8414
8415 if test "x$with_ada_sharedlib" != xno
8416 then
8417         MAKE_ADA_SHAREDLIB=
8418         if test "x$with_ada_sharedlib" != xyes
8419         then
8420                 ADA_SHAREDLIB="$with_ada_sharedlib"
8421         fi
8422 fi
8423
8424 AC_SUBST(ADA_SHAREDLIB)
8425 AC_SUBST(MAKE_ADA_SHAREDLIB)
8426 ])dnl
8427 dnl ---------------------------------------------------------------------------
8428 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
8429 dnl ----------------
8430 dnl Configure-option for dbmalloc.  The optional parameter is used to override
8431 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
8432 AC_DEFUN([CF_WITH_DBMALLOC],[
8433 CF_NO_LEAKS_OPTION(dbmalloc,
8434         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
8435         [USE_DBMALLOC])
8436
8437 if test "$with_dbmalloc" = yes ; then
8438         AC_CHECK_HEADER(dbmalloc.h,
8439                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
8440 fi
8441 ])dnl
8442 dnl ---------------------------------------------------------------------------
8443 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
8444 dnl ---------------
8445 dnl Configure-option for dmalloc.  The optional parameter is used to override
8446 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
8447 AC_DEFUN([CF_WITH_DMALLOC],[
8448 CF_NO_LEAKS_OPTION(dmalloc,
8449         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
8450         [USE_DMALLOC])
8451
8452 if test "$with_dmalloc" = yes ; then
8453         AC_CHECK_HEADER(dmalloc.h,
8454                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
8455 fi
8456 ])dnl
8457 dnl ---------------------------------------------------------------------------
8458 dnl CF_WITH_EXPORT_SYMS version: 3 updated: 2014/12/20 19:16:08
8459 dnl -------------------
8460 dnl Use this with libtool to specify the list of symbols that may be exported.
8461 dnl The input file contains one symbol per line; comments work with "#".
8462 dnl
8463 dnl $1 = basename of the ".sym" file (default $PACKAGE)
8464 AC_DEFUN([CF_WITH_EXPORT_SYMS],
8465 [
8466 AC_MSG_CHECKING(if exported-symbols file should be used)
8467 AC_ARG_WITH(export-syms,
8468         [  --with-export-syms=XXX  limit exported symbols using libtool],
8469         [with_export_syms=$withval],
8470         [with_export_syms=no])
8471 if test "x$with_export_syms" = xyes
8472 then
8473         with_export_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).sym'
8474         AC_SUBST(PACKAGE)
8475 fi
8476 AC_MSG_RESULT($with_export_syms)
8477 if test "x$with_export_syms" != xno
8478 then
8479         EXPORT_SYMS="-export-symbols $with_export_syms"
8480         AC_SUBST(EXPORT_SYMS)
8481 fi
8482 ])dnl
8483 dnl ---------------------------------------------------------------------------
8484 dnl CF_WITH_GPM version: 10 updated: 2017/04/29 18:32:18
8485 dnl -----------
8486 dnl
8487 dnl The option parameter (if neither yes/no) is assumed to be the name of
8488 dnl the gpm library, e.g., for dynamic loading.
8489 AC_DEFUN([CF_WITH_GPM],
8490 [
8491 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
8492 AC_ARG_WITH(gpm,
8493         [  --with-gpm              use Alessandro Rubini's GPM library],
8494         [with_gpm=$withval],
8495         [with_gpm=maybe])
8496 AC_MSG_RESULT($with_gpm)
8497
8498 if test "$with_gpm" != no ; then
8499         AC_CHECK_HEADER(gpm.h,[
8500                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
8501                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
8502                         CF_VERBOSE(assuming we really have GPM library)
8503                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
8504                         with_gpm=yes
8505                 else
8506                         AC_CHECK_LIB(gpm,Gpm_Open,[with_gpm=yes],[
8507                                 if test "$with_gpm" = maybe; then
8508                                         AC_MSG_WARN(Cannot link with GPM library)
8509                                         with_gpm=no
8510                                 else
8511                                         AC_MSG_ERROR(Cannot link with GPM library)
8512                                 fi
8513                         ])
8514                 fi
8515         ],[
8516                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
8517                 with_gpm=no
8518         ])
8519 fi
8520 ])
8521 dnl ---------------------------------------------------------------------------
8522 dnl CF_WITH_LIBTOOL version: 35 updated: 2017/08/12 07:58:51
8523 dnl ---------------
8524 dnl Provide a configure option to incorporate libtool.  Define several useful
8525 dnl symbols for the makefile rules.
8526 dnl
8527 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
8528 dnl macros from libtool.m4 which is in the aclocal directory of automake.
8529 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
8530 dnl But that still does not work properly since the macro is expanded outside
8531 dnl the CF_WITH_LIBTOOL macro:
8532 dnl
8533 dnl     #!/bin/sh
8534 dnl     ACLOCAL=`aclocal --print-ac-dir`
8535 dnl     if test -z "$ACLOCAL" ; then
8536 dnl             echo cannot find aclocal directory
8537 dnl             exit 1
8538 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
8539 dnl             echo cannot find libtool.m4 file
8540 dnl             exit 1
8541 dnl     fi
8542 dnl
8543 dnl     LOCAL=aclocal.m4
8544 dnl     ORIG=aclocal.m4.orig
8545 dnl
8546 dnl     trap "mv $ORIG $LOCAL" 0 1 2 3 15
8547 dnl     rm -f $ORIG
8548 dnl     mv $LOCAL $ORIG
8549 dnl
8550 dnl     # sed the LIBTOOL= assignment to omit the current directory?
8551 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
8552 dnl     cat $ORIG >>$LOCAL
8553 dnl
8554 dnl     autoconf-257 $*
8555 dnl
8556 AC_DEFUN([CF_WITH_LIBTOOL],
8557 [
8558 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
8559 ifdef([AC_PROG_LIBTOOL],,[
8560 LIBTOOL=
8561 ])
8562 # common library maintenance symbols that are convenient for libtool scripts:
8563 LIB_CREATE='${AR} -cr'
8564 LIB_OBJECT='${OBJECTS}'
8565 LIB_SUFFIX=.a
8566 LIB_PREP="$RANLIB"
8567
8568 # symbols used to prop libtool up to enable it to determine what it should be
8569 # doing:
8570 LIB_CLEAN=
8571 LIB_COMPILE=
8572 LIB_LINK='${CC}'
8573 LIB_INSTALL=
8574 LIB_UNINSTALL=
8575
8576 AC_MSG_CHECKING(if you want to build libraries with libtool)
8577 AC_ARG_WITH(libtool,
8578         [  --with-libtool          generate libraries with libtool],
8579         [with_libtool=$withval],
8580         [with_libtool=no])
8581 AC_MSG_RESULT($with_libtool)
8582 if test "$with_libtool" != "no"; then
8583 ifdef([AC_PROG_LIBTOOL],[
8584         # missing_content_AC_PROG_LIBTOOL{{
8585         AC_PROG_LIBTOOL
8586         # missing_content_AC_PROG_LIBTOOL}}
8587 ],[
8588         if test "$with_libtool" != "yes" ; then
8589                 CF_PATH_SYNTAX(with_libtool)
8590                 LIBTOOL=$with_libtool
8591         else
8592                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
8593                 CF_LIBTOOL_VERSION
8594                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
8595                 then
8596                         CF_FORGET_TOOL(LIBTOOL)
8597                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
8598                         CF_LIBTOOL_VERSION
8599                 fi
8600         fi
8601         if test -z "$LIBTOOL" ; then
8602                 AC_MSG_ERROR(Cannot find libtool)
8603         fi
8604 ])dnl
8605         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${libdir} ${LIBTOOL_VERSION} `cut -f1 ${top_srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
8606         LIB_OBJECT='${OBJECTS:.o=.lo}'
8607         LIB_SUFFIX=.la
8608         LIB_CLEAN='${LIBTOOL} --mode=clean'
8609         LIB_COMPILE='${LIBTOOL} --mode=compile'
8610         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
8611         LIB_INSTALL='${LIBTOOL} --mode=install'
8612         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
8613         LIB_PREP=:
8614
8615         CF_CHECK_LIBTOOL_VERSION
8616
8617         # special hack to add -no-undefined (which libtool should do for itself)
8618         LT_UNDEF=
8619         case "$cf_cv_system_name" in
8620         (cygwin*|msys*|mingw32*|os2*|uwin*|aix[[4-7]])
8621                 LT_UNDEF=-no-undefined
8622                 ;;
8623         esac
8624         AC_SUBST([LT_UNDEF])
8625
8626         # special hack to add --tag option for C++ compiler
8627         case $cf_cv_libtool_version in
8628         (1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*)
8629                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
8630                 LIBTOOL="$LIBTOOL --tag=CC"
8631                 ;;
8632         (*)
8633                 LIBTOOL_CXX="$LIBTOOL"
8634                 ;;
8635         esac
8636 else
8637         LIBTOOL=""
8638         LIBTOOL_CXX=""
8639 fi
8640
8641 test -z "$LIBTOOL" && ECHO_LT=
8642
8643 AC_SUBST(LIBTOOL)
8644 AC_SUBST(LIBTOOL_CXX)
8645 AC_SUBST(LIBTOOL_OPTS)
8646
8647 AC_SUBST(LIB_CREATE)
8648 AC_SUBST(LIB_OBJECT)
8649 AC_SUBST(LIB_SUFFIX)
8650 AC_SUBST(LIB_PREP)
8651
8652 AC_SUBST(LIB_CLEAN)
8653 AC_SUBST(LIB_COMPILE)
8654 AC_SUBST(LIB_LINK)
8655 AC_SUBST(LIB_INSTALL)
8656 AC_SUBST(LIB_UNINSTALL)
8657
8658 ])dnl
8659 dnl ---------------------------------------------------------------------------
8660 dnl CF_WITH_LIBTOOL_OPTS version: 4 updated: 2015/04/17 21:13:04
8661 dnl --------------------
8662 dnl Allow user to pass additional libtool options into the library creation
8663 dnl and link steps.  The main use for this is to do something like
8664 dnl     ./configure --with-libtool-opts=-static
8665 dnl to get the same behavior as automake-flavored
8666 dnl     ./configure --enable-static
8667 AC_DEFUN([CF_WITH_LIBTOOL_OPTS],[
8668 AC_MSG_CHECKING(for additional libtool options)
8669 AC_ARG_WITH(libtool-opts,
8670         [  --with-libtool-opts=XXX specify additional libtool options],
8671         [with_libtool_opts=$withval],
8672         [with_libtool_opts=no])
8673 AC_MSG_RESULT($with_libtool_opts)
8674
8675 case .$with_libtool_opts in
8676 (.yes|.no|.)
8677         ;;
8678 (*)
8679         LIBTOOL_OPTS="$LIBTOOL_OPTS $with_libtool_opts"
8680         ;;
8681 esac
8682
8683 AC_SUBST(LIBTOOL_OPTS)
8684 ])dnl
8685 dnl ---------------------------------------------------------------------------
8686 dnl CF_WITH_LIB_BASENAME version: 1 updated: 2020/03/07 20:05:14
8687 dnl --------------------
8688 dnl Allow for overriding the basename of a library, i.e., the part to which
8689 dnl prefixes/suffixes are attached.
8690 dnl
8691 dnl $1 = variable to set
8692 dnl $2 = option name
8693 dnl $3 = default basename for library, if omitted use $2
8694 AC_DEFUN([CF_WITH_LIB_BASENAME],
8695 [
8696 AC_MSG_CHECKING(for desired basename for $2 library)
8697 AC_ARG_WITH($2-libname,
8698         [  --with-$2-libname=XXX override ifelse($3,,$2,$3) basename of library],
8699         [with_lib_basename=$withval],
8700         [with_lib_basename=ifelse($3,,$2,$3)])
8701 $1="$with_lib_basename"
8702
8703 case "x[$]$1" in
8704 (x|xno|xnone|xyes)
8705         $1=ifelse($3,,$2,$3)
8706         ;;
8707 (*)
8708         ;;
8709 esac
8710
8711 AC_MSG_RESULT([$]$1)
8712 AC_SUBST($1)
8713 ])dnl
8714 dnl ---------------------------------------------------------------------------
8715 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
8716 dnl ------------------
8717 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
8718 dnl "lib" prefix, e.g., because it used the dll naming convention.
8719 dnl
8720 dnl $1 = variable to set
8721 AC_DEFUN([CF_WITH_LIB_PREFIX],
8722 [
8723 AC_MSG_CHECKING(if you want to have a library-prefix)
8724 AC_ARG_WITH(lib-prefix,
8725         [  --with-lib-prefix       override library-prefix],
8726         [with_lib_prefix=$withval],
8727         [with_lib_prefix=auto])
8728 AC_MSG_RESULT($with_lib_prefix)
8729
8730 if test $with_lib_prefix = auto
8731 then
8732         CF_LIB_PREFIX($1)
8733 elif test $with_lib_prefix = no
8734 then
8735         LIB_PREFIX=
8736 else
8737         LIB_PREFIX=$with_lib_prefix
8738 fi
8739 ])dnl
8740 dnl ---------------------------------------------------------------------------
8741 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
8742 dnl ------------
8743 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
8744 dnl defaulting to yes/no.
8745 dnl
8746 dnl $1 = option name
8747 dnl $2 = help-text
8748 dnl $3 = environment variable to set
8749 dnl $4 = default value, shown in the help-message, must be a constant
8750 dnl $5 = default value, if it's an expression & cannot be in the help-message
8751 dnl
8752 AC_DEFUN([CF_WITH_PATH],
8753 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
8754 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
8755 if ifelse([$5],,true,[test -n "$5"]) ; then
8756 CF_PATH_SYNTAX(withval)
8757 fi
8758 eval $3="$withval"
8759 AC_SUBST($3)dnl
8760 ])dnl
8761 dnl ---------------------------------------------------------------------------
8762 dnl CF_WITH_PATHLIST version: 10 updated: 2015/04/17 21:13:04
8763 dnl ----------------
8764 dnl Process an option specifying a list of colon-separated paths.
8765 dnl
8766 dnl $1 = option name
8767 dnl $2 = help-text
8768 dnl $3 = environment variable to set
8769 dnl $4 = default value, shown in the help-message, must be a constant
8770 dnl $5 = default value, if it's an expression & cannot be in the help-message
8771 dnl $6 = flag to tell if we want to define or substitute
8772 dnl
8773 AC_DEFUN([CF_WITH_PATHLIST],[
8774 AC_REQUIRE([CF_PATHSEP])
8775 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
8776 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
8777
8778 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
8779 cf_dst_path=
8780 for cf_src_path in $withval
8781 do
8782   CF_PATH_SYNTAX(cf_src_path)
8783   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
8784   cf_dst_path="${cf_dst_path}${cf_src_path}"
8785 done
8786 IFS="$ac_save_ifs"
8787
8788 ifelse($6,define,[
8789 # Strip single quotes from the value, e.g., when it was supplied as a literal
8790 # for $4 or $5.
8791 case $cf_dst_path in
8792 (\'*)
8793   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
8794   ;;
8795 esac
8796 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
8797 ])
8798
8799 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
8800 # so we have to check/work around.  We do prefer the result of "eval"...
8801 eval cf_dst_eval="$cf_dst_path"
8802 case "x$cf_dst_eval" in
8803 (xNONE*)
8804         $3=$cf_dst_path
8805         ;;
8806 (*)
8807         $3="$cf_dst_eval"
8808         ;;
8809 esac
8810 AC_SUBST($3)dnl
8811
8812 ])dnl
8813 dnl ---------------------------------------------------------------------------
8814 dnl CF_WITH_PATH_PROG version: 1 updated: 2019/06/30 19:44:43
8815 dnl -----------------
8816 dnl Check for a given program, like CF_PATH_PROG, but allow override using a
8817 dnl "--with-xxx" option.
8818 dnl
8819 dnl Parameters:
8820 dnl             $1 = environment variable to set/update
8821 dnl             $2 = program name
8822 dnl             $3 = help-text
8823 dnl             $4 = $PATH
8824 AC_DEFUN([CF_WITH_PATH_PROG],[
8825 AC_ARG_WITH($2-path,
8826         [  --with-$2-path=XXX     specify path of $2 ifelse($3,,,$3)],
8827         [AC_MSG_CHECKING(for $2 program ifelse($3,,,$3))
8828                 $1=$withval
8829                 AC_MSG_RESULT([$]$1)
8830                 CF_PATH_SYNTAX($1)
8831         ],
8832         [CF_PATH_PROG($1,$2,,ifelse($4,,,$4))
8833                 if test -z "[$]$1"
8834                 then
8835                         AC_MSG_WARN(no $2 program found ifelse($3,,,$3))
8836                 fi
8837         ])
8838 ])
8839 dnl ---------------------------------------------------------------------------
8840 dnl CF_WITH_PCRE2 version: 3 updated: 2020/02/29 16:09:19
8841 dnl -------------
8842 dnl Add PCRE2 (Perl-compatible regular expressions v2) to the build if it is
8843 dnl available and the user requests it.  Assume the application will otherwise
8844 dnl use the POSIX interface.
8845 dnl
8846 dnl TODO allow $withval to specify package location
8847 AC_DEFUN([CF_WITH_PCRE2],
8848 [
8849 AC_REQUIRE([CF_PKG_CONFIG])
8850
8851 AC_MSG_CHECKING(if you want to use PCRE2 for regular-expressions)
8852 AC_ARG_WITH(pcre2,
8853         [  --with-pcre2            use PCRE2 for regular-expressions])
8854 test -z "$with_pcre2" && with_pcre2=no
8855 AC_MSG_RESULT($with_pcre2)
8856
8857 if test "x$with_pcre2" != xno ; then
8858         CF_TRY_PKG_CONFIG(libpcre2,,[
8859         CF_TRY_PKG_CONFIG(libpcre,,[
8860                         AC_MSG_ERROR(Cannot find PCRE2 library)])])
8861
8862         AC_DEFINE(HAVE_LIB_PCRE2,1,[Define to 1 if we can/should compile with the PCRE2 library])
8863
8864         # if pkgconfig gave no results, look for the libraries directly
8865         case $LIBS in
8866         (*pcre2-posix*|*pcreposix*)
8867                 ;;
8868         (*)
8869                 AC_CHECK_LIB(pcre2-posix,regcomp,[
8870                         CF_ADD_LIB(pcre2-posix)],
8871                         [AC_CHECK_LIB(pcreposix,regcomp,[
8872                          CF_ADD_LIB(pcreposix)
8873                         ],[AC_MSG_ERROR(Cannot find PCRE2 POSIX library)])])
8874                 ;;
8875         esac
8876
8877         # either way, check for the library header files
8878         AC_CHECK_HEADERS(pcre2posix.h pcreposix.h)
8879 fi
8880 ])dnl
8881 dnl ---------------------------------------------------------------------------
8882 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 10 updated: 2015/08/22 17:10:56
8883 dnl -------------------------
8884 dnl Allow the choice of the pkg-config library directory to be overridden.
8885 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
8886
8887 case $PKG_CONFIG in
8888 (no|none|yes)
8889         AC_MSG_CHECKING(for pkg-config library directory)
8890         ;;
8891 (*)
8892         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
8893         ;;
8894 esac
8895
8896 PKG_CONFIG_LIBDIR=no
8897 AC_ARG_WITH(pkg-config-libdir,
8898         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
8899         [PKG_CONFIG_LIBDIR=$withval],
8900         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
8901
8902 case x$PKG_CONFIG_LIBDIR in
8903 (x/*)
8904         ;;
8905 (xyes)
8906         # Look for the library directory using the same prefix as the executable
8907         if test "x$PKG_CONFIG" = xnone
8908         then
8909                 cf_path=$prefix
8910         else
8911                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
8912         fi
8913
8914         # If you don't like using the default architecture, you have to specify the
8915         # intended library directory and corresponding compiler/linker options.
8916         #
8917         # This case allows for Debian's 2014-flavor of multiarch, along with the
8918         # most common variations before that point.  Some other variants spell the
8919         # directory differently, e.g., "pkg-config", and put it in unusual places.
8920         # pkg-config has always been poorly standardized, which is ironic...
8921         case x`(arch) 2>/dev/null` in
8922         (*64)
8923                 cf_search_path="\
8924                         $cf_path/lib/*64-linux-gnu \
8925                         $cf_path/share \
8926                         $cf_path/lib64 \
8927                         $cf_path/lib32 \
8928                         $cf_path/lib"
8929                 ;;
8930         (*)
8931                 cf_search_path="\
8932                         $cf_path/lib/*-linux-gnu \
8933                         $cf_path/share \
8934                         $cf_path/lib32 \
8935                         $cf_path/lib \
8936                         $cf_path/libdata"
8937                 ;;
8938         esac
8939
8940         CF_VERBOSE(list...)
8941         for cf_config in $cf_search_path
8942         do
8943                 CF_VERBOSE(checking $cf_config/pkgconfig)
8944                 if test -d $cf_config/pkgconfig
8945                 then
8946                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
8947                         AC_MSG_CHECKING(done)
8948                         break
8949                 fi
8950         done
8951         ;;
8952 (*)
8953         ;;
8954 esac
8955
8956 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
8957         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
8958 fi
8959
8960 AC_SUBST(PKG_CONFIG_LIBDIR)
8961 ])dnl
8962 dnl ---------------------------------------------------------------------------
8963 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
8964 dnl ---------------
8965 dnl Check for POSIX thread library.
8966 AC_DEFUN([CF_WITH_PTHREAD],
8967 [
8968 AC_MSG_CHECKING(if you want to link with the pthread library)
8969 AC_ARG_WITH(pthread,
8970         [  --with-pthread          use POSIX thread library],
8971         [with_pthread=$withval],
8972         [with_pthread=no])
8973 AC_MSG_RESULT($with_pthread)
8974
8975 if test "$with_pthread" != no ; then
8976         AC_CHECK_HEADER(pthread.h,[
8977         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
8978
8979         for cf_lib_pthread in pthread c_r
8980         do
8981             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
8982             cf_save_LIBS="$LIBS"
8983             CF_ADD_LIB($cf_lib_pthread)
8984             AC_TRY_LINK([
8985 #include <pthread.h>
8986 ],[
8987                 int rc = pthread_create(0,0,0,0);
8988                 int r2 = pthread_mutexattr_settype(0, 0);
8989 ],[with_pthread=yes],[with_pthread=no])
8990             LIBS="$cf_save_LIBS"
8991             AC_MSG_RESULT($with_pthread)
8992             test "$with_pthread" = yes && break
8993         done
8994
8995         if test "$with_pthread" = yes ; then
8996             CF_ADD_LIB($cf_lib_pthread)
8997             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
8998         else
8999             AC_MSG_ERROR(Cannot link with pthread library)
9000         fi
9001         ])
9002 fi
9003 ])
9004 dnl ---------------------------------------------------------------------------
9005 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
9006 dnl -------------------
9007 dnl Allow library's release-version to be overridden.  Generally this happens when a
9008 dnl packager has incremented the release-version past that used in the original package,
9009 dnl and wishes to keep doing this.
9010 dnl
9011 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
9012 dnl and {package}_MINOR symbols
9013 dnl symbol.
9014 AC_DEFUN([CF_WITH_REL_VERSION],[
9015 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
9016 AC_ARG_WITH(rel-version,
9017 [  --with-rel-version=XXX  override derived release version],
9018 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
9019  cf_cv_rel_version=$withval])
9020 ifelse($1,,[
9021  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
9022 ],[
9023  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
9024  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
9025  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
9026  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
9027 ])
9028 ])dnl
9029 dnl ---------------------------------------------------------------------------
9030 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
9031 dnl ----------------
9032 dnl If we can compile with sysmouse, make it available unless it is not wanted.
9033 AC_DEFUN([CF_WITH_SYSMOUSE],[
9034 # not everyone has "test -c"
9035 if test -c /dev/sysmouse 2>/dev/null ; then
9036 AC_MSG_CHECKING(if you want to use sysmouse)
9037 AC_ARG_WITH(sysmouse,
9038         [  --with-sysmouse         use sysmouse (FreeBSD console)],
9039         [cf_with_sysmouse=$withval],
9040         [cf_with_sysmouse=maybe])
9041         if test "$cf_with_sysmouse" != no ; then
9042         AC_TRY_COMPILE([
9043 #include <osreldate.h>
9044 #if (__FreeBSD_version >= 400017)
9045 #include <sys/consio.h>
9046 #include <sys/fbio.h>
9047 #else
9048 #include <machine/console.h>
9049 #endif
9050 ],[
9051         struct mouse_info the_mouse;
9052         ioctl(0, CONS_MOUSECTL, &the_mouse);
9053 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
9054         fi
9055 AC_MSG_RESULT($cf_with_sysmouse)
9056 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
9057 fi
9058 ])dnl
9059 dnl ---------------------------------------------------------------------------
9060 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
9061 dnl ---------------
9062 dnl For testing, override the derived host system-type which is used to decide
9063 dnl things such as the linker commands used to build shared libraries.  This is
9064 dnl normally chosen automatically based on the type of system which you are
9065 dnl building on.  We use it for testing the configure script.
9066 dnl
9067 dnl This is different from the --host option: it is used only for testing parts
9068 dnl of the configure script which would not be reachable with --host since that
9069 dnl relies on the build environment being real, rather than mocked up.
9070 AC_DEFUN([CF_WITH_SYSTYPE],[
9071 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
9072 AC_ARG_WITH(system-type,
9073         [  --with-system-type=XXX  test: override derived host system-type],
9074 [AC_MSG_WARN(overriding system type to $withval)
9075         cf_cv_system_name=$withval
9076         host_os=$withval
9077 ])
9078 ])dnl
9079 dnl ---------------------------------------------------------------------------
9080 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
9081 dnl ----------------
9082 AC_DEFUN([CF_WITH_VALGRIND],[
9083 CF_NO_LEAKS_OPTION(valgrind,
9084         [  --with-valgrind         test: use valgrind],
9085         [USE_VALGRIND])
9086 ])dnl
9087 dnl ---------------------------------------------------------------------------
9088 dnl CF_WITH_VERSIONED_SYMS version: 8 updated: 2018/10/20 20:24:34
9089 dnl ----------------------
9090 dnl Use this when building shared library with ELF, to markup symbols with the
9091 dnl version identifier from the given input file.  Generally that identifier is
9092 dnl the same as the SONAME at which the symbol was first introduced.
9093 dnl
9094 dnl $1 = basename of the ".map" file (default $PACKAGE)
9095 AC_DEFUN([CF_WITH_VERSIONED_SYMS],
9096 [
9097 AC_MSG_CHECKING(if versioned-symbols file should be used)
9098 AC_ARG_WITH(versioned-syms,
9099         [  --with-versioned-syms=X markup versioned symbols using ld],
9100         [with_versioned_syms=$withval],
9101         [with_versioned_syms=no])
9102 case "x$with_versioned_syms" in
9103 (xyes)
9104         with_versioned_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).map'
9105         AC_SUBST(PACKAGE)
9106         ;;
9107 (xno)
9108         ;;
9109 (x/*)
9110         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
9111         ;;
9112 (*)
9113         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
9114         with_versioned_syms=`pwd`/"$with_versioned_syms"
9115         ;;
9116 esac
9117 AC_MSG_RESULT($with_versioned_syms)
9118
9119 RESULTING_SYMS=
9120 VERSIONED_SYMS=
9121 WILDCARD_SYMS=
9122
9123 if test "x$with_versioned_syms" != xno
9124 then
9125         RESULTING_SYMS=$with_versioned_syms
9126         case "x$MK_SHARED_LIB" in
9127         (*-Wl,*)
9128                 VERSIONED_SYMS="-Wl,--version-script,\${RESULTING_SYMS}"
9129                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-Wl,%\\[$]{VERSIONED_SYMS} -Wl,%"`
9130                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
9131                 ;;
9132         (*-dy\ *)
9133                 VERSIONED_SYMS="-Wl,-M,\${RESULTING_SYMS}"
9134                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-dy%\\[$]{VERSIONED_SYMS} -dy%"`
9135                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
9136                 ;;
9137         (*)
9138                 AC_MSG_WARN(this system does not support versioned-symbols)
9139                 ;;
9140         esac
9141
9142         # Linux ld can selectively override scope, e.g., of symbols beginning with
9143         # "_" by first declaring some as global, and then using a wildcard to
9144         # declare the others as local.  Some other loaders cannot do this.  Check
9145         # by constructing a (very) simple shared library and inspecting its
9146         # symbols.
9147         if test "x$VERSIONED_SYMS" != "x"
9148         then
9149                 AC_MSG_CHECKING(if wildcards can be used to selectively omit symbols)
9150                 WILDCARD_SYMS=no
9151
9152                 # make sources
9153                 rm -f conftest.*
9154
9155                 cat >conftest.ver <<EOF
9156 module_1.0 {
9157 global:
9158         globalf1;
9159 local:
9160         localf1;
9161 };
9162 module_2.0 {
9163 global:
9164         globalf2;
9165 local:
9166         localf2;
9167         _*;
9168 } module_1.0;
9169 submodule_1.0 {
9170 global:
9171         subglobalf1;
9172         _ismissing;
9173 local:
9174         sublocalf1;
9175 };
9176 submodule_2.0 {
9177 global:
9178         subglobalf2;
9179 local:
9180         sublocalf2;
9181         _*;
9182 } submodule_1.0;
9183 EOF
9184                 cat >conftest.$ac_ext <<EOF
9185 #line __oline__ "configure"
9186 int     _ismissing(void) { return 1; }
9187 int     _localf1(void) { return 1; }
9188 int     _localf2(void) { return 2; }
9189 int     globalf1(void) { return 1; }
9190 int     globalf2(void) { return 2; }
9191 int     _sublocalf1(void) { return 1; }
9192 int     _sublocalf2(void) { return 2; }
9193 int     subglobalf1(void) { return 1; }
9194 int     subglobalf2(void) { return 2; }
9195 EOF
9196                 cat >conftest.mk <<EOF
9197 CC=${CC}
9198 CFLAGS=${CFLAGS}
9199 CPPFLAGS=${CPPFLAGS}
9200 LDFLAGS=${LDFLAGS}
9201 LIBS=${LIBS}
9202 VERSIONED_SYMS=${VERSIONED_SYMS}
9203 RESULTING_SYMS=conftest.ver
9204 MK_SHARED_LIB=${MK_SHARED_LIB}
9205 conftest.so: conftest.$ac_cv_objext
9206                 \$(MK_SHARED_LIB) conftest.$ac_cv_objext
9207 EOF
9208
9209                 # compile source, make library
9210                 if make -f conftest.mk 2>&AC_FD_CC >/dev/null
9211                 then
9212                         # test for missing symbol in either Data or Text section
9213                         cf_missing=`nm -P conftest.so 2>&AC_FD_CC |fgrep _ismissing | egrep '[[         ]][[DT]][[      ]]'`
9214                         test -n "$cf_missing" && WILDCARD_SYMS=yes
9215                 fi
9216                 AC_MSG_RESULT($WILDCARD_SYMS)
9217                 rm -f conftest.*
9218         fi
9219 fi
9220 AC_SUBST(RESULTING_SYMS)
9221 AC_SUBST(VERSIONED_SYMS)
9222 AC_SUBST(WILDCARD_SYMS)
9223 ])dnl
9224 dnl ---------------------------------------------------------------------------
9225 dnl CF_WITH_X11_RGB version: 2 updated: 2019/12/31 08:53:54
9226 dnl ---------------
9227 dnl Handle configure option "--with-x11-rgb", setting these shell
9228 dnl variables:
9229 dnl
9230 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
9231 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
9232 dnl
9233 dnl Most Linux's use this:
9234 dnl     /usr/share/X11/rgb.txt
9235 dnl Debian uses this:
9236 dnl     /etc/X11/rgb.txt
9237 dnl DragonFlyBSD ports uses this:
9238 dnl     /usr/pkg/lib/X11/rgb.txt
9239 dnl FreeBSD ports use these:
9240 dnl     /usr/local/lib/X11/rgb.txt
9241 dnl     /usr/local/share/X11/rgb.txt
9242 dnl Mandriva has these:
9243 dnl     /usr/lib/X11/rgb.txt
9244 dnl     /usr/lib64/X11/rgb.txt
9245 dnl NetBSD has these
9246 dnl     /usr/X11R7/lib/X11/rgb.txt
9247 dnl OpenSolaris uses
9248 dnl     32-bit:
9249 dnl     /usr/X11/etc/X11/rgb.txt
9250 dnl     /usr/X11/share/X11/rgb.txt
9251 dnl     /usr/X11/lib/X11/rgb.txt
9252 dnl OSX uses
9253 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
9254 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
9255 dnl     64-bit:
9256 dnl     /usr/X11/etc/X11/rgb.txt
9257 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
9258 dnl     /usr/X11/lib/amd64/X11/rgb.txt
9259 dnl Solaris10 uses (in this order):
9260 dnl     /usr/openwin/lib/X11/rgb.txt
9261 dnl     /usr/X11/lib/X11/rgb.txt
9262 AC_DEFUN([CF_WITH_X11_RGB],[
9263 AC_MSG_CHECKING(for X11 rgb file)
9264 AC_ARG_WITH(x11-rgb,
9265         [  --with-x11-rgb=FILE   file containing X11 rgb information (EPREFIX/lib/X11/rgb.txt)],
9266         [RGB_PATH=$withval],
9267         [RGB_PATH=auto])
9268
9269 if test "x[$]RGB_PATH" = xauto
9270 then
9271         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
9272         for cf_path in \
9273                 /opt/local/share/X11/rgb.txt \
9274                 /opt/X11/share/X11/rgb.txt \
9275                 /usr/share/X11/rgb.txt \
9276                 /usr/X11/share/X11/rgb.txt \
9277                 /usr/X11/lib/X11/rgb.txt \
9278                 /usr/lib/X11/rgb.txt \
9279                 /etc/X11/rgb.txt \
9280                 /usr/pkg/lib/X11/rgb.txt \
9281                 /usr/X11R7/lib/X11/rgb.txt \
9282                 /usr/X11R6/lib/X11/rgb.txt \
9283                 /usr/X11R5/lib/X11/rgb.txt \
9284                 /usr/X11R4/lib/X11/rgb.txt \
9285                 /usr/local/lib/X11/rgb.txt \
9286                 /usr/local/share/X11/rgb.txt \
9287                 /usr/lib64/X11/rgb.txt
9288         do
9289                 if test -f "$cf_path" ; then
9290                         RGB_PATH="$cf_path"
9291                         break
9292                 fi
9293         done
9294 else
9295         cf_path=$RGB_PATH
9296         CF_PATH_SYNTAX(cf_path)
9297 fi
9298
9299 AC_MSG_RESULT($RGB_PATH)
9300 AC_SUBST(RGB_PATH)
9301 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path",[Define to the full pathname of rgb.txt])
9302
9303 no_x11_rgb=
9304 if test "$RGB_PATH" = no
9305 then
9306         no_x11_rgb="#"
9307 fi
9308 AC_SUBST(no_x11_rgb)
9309 ])dnl
9310 dnl ---------------------------------------------------------------------------
9311 dnl CF_XOPEN_SOURCE version: 55 updated: 2018/12/31 20:46:17
9312 dnl ---------------
9313 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
9314 dnl or adapt to the vendor's definitions to get equivalent functionality,
9315 dnl without losing the common non-POSIX features.
9316 dnl
9317 dnl Parameters:
9318 dnl     $1 is the nominal value for _XOPEN_SOURCE
9319 dnl     $2 is the nominal value for _POSIX_C_SOURCE
9320 AC_DEFUN([CF_XOPEN_SOURCE],[
9321 AC_REQUIRE([AC_CANONICAL_HOST])
9322 AC_REQUIRE([CF_POSIX_VISIBLE])
9323
9324 if test "$cf_cv_posix_visible" = no; then
9325
9326 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
9327 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
9328 cf_xopen_source=
9329
9330 case $host_os in
9331 (aix[[4-7]]*)
9332         cf_xopen_source="-D_ALL_SOURCE"
9333         ;;
9334 (msys)
9335         cf_XOPEN_SOURCE=600
9336         ;;
9337 (darwin[[0-8]].*)
9338         cf_xopen_source="-D_APPLE_C_SOURCE"
9339         ;;
9340 (darwin*)
9341         cf_xopen_source="-D_DARWIN_C_SOURCE"
9342         cf_XOPEN_SOURCE=
9343         ;;
9344 (freebsd*|dragonfly*|midnightbsd*)
9345         # 5.x headers associate
9346         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
9347         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
9348         cf_POSIX_C_SOURCE=200112L
9349         cf_XOPEN_SOURCE=600
9350         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
9351         ;;
9352 (hpux11*)
9353         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
9354         ;;
9355 (hpux*)
9356         cf_xopen_source="-D_HPUX_SOURCE"
9357         ;;
9358 (irix[[56]].*)
9359         cf_xopen_source="-D_SGI_SOURCE"
9360         cf_XOPEN_SOURCE=
9361         ;;
9362 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
9363         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
9364         ;;
9365 (minix*)
9366         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
9367         ;;
9368 (mirbsd*)
9369         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
9370         cf_XOPEN_SOURCE=
9371         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
9372         ;;
9373 (netbsd*)
9374         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
9375         ;;
9376 (openbsd[[4-9]]*)
9377         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
9378         cf_xopen_source="-D_BSD_SOURCE"
9379         cf_XOPEN_SOURCE=600
9380         ;;
9381 (openbsd*)
9382         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
9383         ;;
9384 (osf[[45]]*)
9385         cf_xopen_source="-D_OSF_SOURCE"
9386         ;;
9387 (nto-qnx*)
9388         cf_xopen_source="-D_QNX_SOURCE"
9389         ;;
9390 (sco*)
9391         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
9392         ;;
9393 (solaris2.*)
9394         cf_xopen_source="-D__EXTENSIONS__"
9395         cf_cv_xopen_source=broken
9396         ;;
9397 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
9398         cf_XOPEN_SOURCE=
9399         cf_POSIX_C_SOURCE=
9400         ;;
9401 (*)
9402         CF_TRY_XOPEN_SOURCE
9403         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
9404         ;;
9405 esac
9406
9407 if test -n "$cf_xopen_source" ; then
9408         CF_ADD_CFLAGS($cf_xopen_source,true)
9409 fi
9410
9411 dnl In anything but the default case, we may have system-specific setting
9412 dnl which is still not guaranteed to provide all of the entrypoints that
9413 dnl _XOPEN_SOURCE would yield.
9414 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
9415         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
9416         AC_TRY_COMPILE([#include <stdlib.h>],[
9417 #ifndef _XOPEN_SOURCE
9418 make an error
9419 #endif],
9420         [cf_XOPEN_SOURCE_set=yes],
9421         [cf_XOPEN_SOURCE_set=no])
9422         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
9423         if test $cf_XOPEN_SOURCE_set = yes
9424         then
9425                 AC_TRY_COMPILE([#include <stdlib.h>],[
9426 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
9427 make an error
9428 #endif],
9429                 [cf_XOPEN_SOURCE_set_ok=yes],
9430                 [cf_XOPEN_SOURCE_set_ok=no])
9431                 if test $cf_XOPEN_SOURCE_set_ok = no
9432                 then
9433                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
9434                 fi
9435         else
9436                 CF_TRY_XOPEN_SOURCE
9437         fi
9438 fi
9439 fi # cf_cv_posix_visible
9440 ])