aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2011,2012 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.605 2012/02/18 23:06:14 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 3 updated: 2002/10/27 23:21:42
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54     [AC_TRY_LINK([#include <langinfo.h>],
  55       [char* cs = nl_langinfo(CODESET);],
  56       am_cv_langinfo_codeset=yes,
  57       am_cv_langinfo_codeset=no)
  58     ])
  59   if test $am_cv_langinfo_codeset = yes; then
  60     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62   fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ACVERSION_CHECK version: 2 updated: 2011/05/08 11:22:03
  66 dnl ------------------
  67 dnl Conditionally generate script according to whether we're using a given autoconf.
  68 dnl
  69 dnl $1 = version to compare against
  70 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  71 dnl $3 = code to use if AC_ACVERSION is older than $1.
  72 define(CF_ACVERSION_CHECK,
  73 [
  74 ifdef([m4_version_compare],
  75 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  76 [CF_ACVERSION_COMPARE(
  77 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  78 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  79 dnl ---------------------------------------------------------------------------
  80 dnl CF_ACVERSION_COMPARE version: 2 updated: 2011/04/14 20:56:50
  81 dnl --------------------
  82 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  83 dnl                      MAJOR2, MINOR2, TERNARY2,
  84 dnl                      PRINTABLE2, not FOUND, FOUND)
  85 define(CF_ACVERSION_COMPARE,
  86 [ifelse(builtin([eval], [$2 < $5]), 1,
  87 [ifelse([$8], , ,[$8])],
  88 [ifelse([$9], , ,[$9])])])dnl
  89 dnl ---------------------------------------------------------------------------
  90 dnl CF_ADA_INCLUDE_DIRS version: 6 updated: 2010/02/26 19:52:07
  91 dnl -------------------
  92 dnl Construct the list of include-options for the C programs in the Ada95
  93 dnl binding.
  94 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  95 [
  96 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  97 if test "$srcdir" != "."; then
  98         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  99 fi
 100 if test "$GCC" != yes; then
 101         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 102 elif test "$includedir" != "/usr/include"; then
 103         if test "$includedir" = '${prefix}/include' ; then
 104                 if test $prefix != /usr ; then
 105                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 106                 fi
 107         else
 108                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 109         fi
 110 fi
 111 AC_SUBST(ACPPFLAGS)
 112 ])dnl
 113 dnl ---------------------------------------------------------------------------
 114 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 115 dnl ---------------
 116 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 117 AC_DEFUN([CF_ADD_ADAFLAGS],[
 118         ADAFLAGS="$ADAFLAGS $1"
 119         AC_SUBST(ADAFLAGS)
 120 ])dnl
 121 dnl ---------------------------------------------------------------------------
 122 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
 123 dnl -------------
 124 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 125 dnl The second parameter if given makes this macro verbose.
 126 dnl
 127 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 128 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 129 dnl confused by the quotes (which require backslashes to keep them usable).
 130 AC_DEFUN([CF_ADD_CFLAGS],
 131 [
 132 cf_fix_cppflags=no
 133 cf_new_cflags=
 134 cf_new_cppflags=
 135 cf_new_extra_cppflags=
 136
 137 for cf_add_cflags in $1
 138 do
 139 case $cf_fix_cppflags in
 140 no)
 141         case $cf_add_cflags in #(vi
 142         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
 143                 case $cf_add_cflags in
 144                 -D*)
 145                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 146
 147                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 148                                 && test -z "${cf_tst_cflags}" \
 149                                 && cf_fix_cppflags=yes
 150
 151                         if test $cf_fix_cppflags = yes ; then
 152                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 153                                 continue
 154                         elif test "${cf_tst_cflags}" = "\"'" ; then
 155                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 156                                 continue
 157                         fi
 158                         ;;
 159                 esac
 160                 case "$CPPFLAGS" in
 161                 *$cf_add_cflags) #(vi
 162                         ;;
 163                 *) #(vi
 164                         case $cf_add_cflags in #(vi
 165                         -D*)
 166                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 167                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 168                                 ;;
 169                         esac
 170                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 171                         ;;
 172                 esac
 173                 ;;
 174         *)
 175                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 176                 ;;
 177         esac
 178         ;;
 179 yes)
 180         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 181
 182         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 183
 184         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 185                 && test -z "${cf_tst_cflags}" \
 186                 && cf_fix_cppflags=no
 187         ;;
 188 esac
 189 done
 190
 191 if test -n "$cf_new_cflags" ; then
 192         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 193         CFLAGS="$CFLAGS $cf_new_cflags"
 194 fi
 195
 196 if test -n "$cf_new_cppflags" ; then
 197         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 198         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 199 fi
 200
 201 if test -n "$cf_new_extra_cppflags" ; then
 202         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 203         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 204 fi
 205
 206 AC_SUBST(EXTRA_CPPFLAGS)
 207
 208 ])dnl
 209 dnl ---------------------------------------------------------------------------
 210 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 211 dnl -------------
 212 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 213 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 214 dnl but old versions (and some misinstalled ones) need that.  To make things
 215 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 216 dnl the include-path).
 217 AC_DEFUN([CF_ADD_INCDIR],
 218 [
 219 if test -n "$1" ; then
 220   for cf_add_incdir in $1
 221   do
 222         while test $cf_add_incdir != /usr/include
 223         do
 224           if test -d $cf_add_incdir
 225           then
 226                 cf_have_incdir=no
 227                 if test -n "$CFLAGS$CPPFLAGS" ; then
 228                   # a loop is needed to ensure we can add subdirs of existing dirs
 229                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 230                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 231                           cf_have_incdir=yes; break
 232                         fi
 233                   done
 234                 fi
 235
 236                 if test "$cf_have_incdir" = no ; then
 237                   if test "$cf_add_incdir" = /usr/local/include ; then
 238                         if test "$GCC" = yes
 239                         then
 240                           cf_save_CPPFLAGS=$CPPFLAGS
 241                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 242                           AC_TRY_COMPILE([#include <stdio.h>],
 243                                   [printf("Hello")],
 244                                   [],
 245                                   [cf_have_incdir=yes])
 246                           CPPFLAGS=$cf_save_CPPFLAGS
 247                         fi
 248                   fi
 249                 fi
 250
 251                 if test "$cf_have_incdir" = no ; then
 252                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 253                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 254
 255                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 256                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 257                   cf_add_incdir="$cf_top_incdir"
 258                 else
 259                   break
 260                 fi
 261           fi
 262         done
 263   done
 264 fi
 265 ])dnl
 266 dnl ---------------------------------------------------------------------------
 267 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 268 dnl ----------
 269 dnl Add a library, used to enforce consistency.
 270 dnl
 271 dnl $1 = library to add, without the "-l"
 272 dnl $2 = variable to update (default $LIBS)
 273 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 274 dnl ---------------------------------------------------------------------------
 275 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 276 dnl -------------
 277 dnl     Adds to the library-path
 278 dnl
 279 dnl     Some machines have trouble with multiple -L options.
 280 dnl
 281 dnl $1 is the (list of) directory(s) to add
 282 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 283 dnl
 284 AC_DEFUN([CF_ADD_LIBDIR],
 285 [
 286 if test -n "$1" ; then
 287   for cf_add_libdir in $1
 288   do
 289     if test $cf_add_libdir = /usr/lib ; then
 290       :
 291     elif test -d $cf_add_libdir
 292     then
 293       cf_have_libdir=no
 294       if test -n "$LDFLAGS$LIBS" ; then
 295         # a loop is needed to ensure we can add subdirs of existing dirs
 296         for cf_test_libdir in $LDFLAGS $LIBS ; do
 297           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 298             cf_have_libdir=yes; break
 299           fi
 300         done
 301       fi
 302       if test "$cf_have_libdir" = no ; then
 303         CF_VERBOSE(adding $cf_add_libdir to library-path)
 304         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 305       fi
 306     fi
 307   done
 308 fi
 309 ])dnl
 310 dnl ---------------------------------------------------------------------------
 311 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 312 dnl -----------
 313 dnl Add one or more libraries, used to enforce consistency.
 314 dnl
 315 dnl $1 = libraries to add, with the "-l", etc.
 316 dnl $2 = variable to update (default $LIBS)
 317 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 318 dnl ---------------------------------------------------------------------------
 319 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
 320 dnl ------------------
 321 dnl Append to a search-list for a nonstandard header/lib-file
 322 dnl     $1 = the variable to return as result
 323 dnl     $2 = the package name
 324 dnl     $3 = the subdirectory, e.g., bin, include or lib
 325 dnl $4 = the directory under which we will test for subdirectories
 326 dnl $5 = a directory that we do not want $4 to match
 327 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 328 [
 329 test "$4" != "$5" && \
 330 test -d "$4" && \
 331 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
 332         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 333         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 334         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 335         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 336         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 337         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 338 }
 339 ])dnl
 340 dnl ---------------------------------------------------------------------------
 341 dnl CF_ANSI_CC_CHECK version: 11 updated: 2011/07/01 19:47:45
 342 dnl ----------------
 343 dnl This was originally adapted from the macros 'fp_PROG_CC_STDC' and
 344 dnl 'fp_C_PROTOTYPES' in the sharutils 4.2 distribution.
 345 AC_DEFUN([CF_ANSI_CC_CHECK],
 346 [
 347 # This should have been defined by AC_PROG_CC
 348 : ${CC:=cc}
 349
 350 # Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 351 # into CC.  This will not help with broken scripts that wrap the compiler with
 352 # options, but eliminates a more common category of user confusion.
 353 AC_MSG_CHECKING(\$CC variable)
 354 case "$CC" in #(vi
 355 *[[\ \  ]]-[[IUD]]*)
 356         AC_MSG_RESULT(broken)
 357         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 358         # humor him...
 359         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 360         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 361         CF_ADD_CFLAGS($cf_flags)
 362         ;;
 363 *)
 364         AC_MSG_RESULT(ok)
 365         ;;
 366 esac
 367
 368 AC_CACHE_CHECK(for ${CC:-cc} option to accept ANSI C, cf_cv_ansi_cc,[
 369 cf_cv_ansi_cc=no
 370 cf_save_CFLAGS="$CFLAGS"
 371 cf_save_CPPFLAGS="$CPPFLAGS"
 372 # Don't try gcc -ansi; that turns off useful extensions and
 373 # breaks some systems' header files.
 374 # AIX                   -qlanglvl=ansi
 375 # Ultrix and OSF/1      -std1
 376 # HP-UX                 -Aa -D_HPUX_SOURCE
 377 # SVR4                  -Xc
 378 # UnixWare 1.2          (cannot use -Xc, since ANSI/POSIX clashes)
 379 for cf_arg in "-DCC_HAS_PROTOS" \
 380         "" \
 381         -qlanglvl=ansi \
 382         -std1 \
 383         -Ae \
 384         "-Aa -D_HPUX_SOURCE" \
 385         -Xc
 386 do
 387         CF_ADD_CFLAGS($cf_arg)
 388         AC_TRY_COMPILE(
 389 [
 390 #ifndef CC_HAS_PROTOS
 391 #if !defined(__STDC__) || (__STDC__ != 1)
 392 choke me
 393 #endif
 394 #endif
 395 ],[
 396         int test (int i, double x);
 397         struct s1 {int (*f) (int a);};
 398         struct s2 {int (*f) (double a);};],
 399         [cf_cv_ansi_cc="$cf_arg"; break])
 400 done
 401 CFLAGS="$cf_save_CFLAGS"
 402 CPPFLAGS="$cf_save_CPPFLAGS"
 403 ])
 404
 405 if test "$cf_cv_ansi_cc" != "no"; then
 406 if test ".$cf_cv_ansi_cc" != ".-DCC_HAS_PROTOS"; then
 407         CF_ADD_CFLAGS($cf_cv_ansi_cc)
 408 else
 409         AC_DEFINE(CC_HAS_PROTOS)
 410 fi
 411 fi
 412 ])dnl
 413 dnl ---------------------------------------------------------------------------
 414 dnl CF_ANSI_CC_REQD version: 4 updated: 2008/03/23 14:48:54
 415 dnl ---------------
 416 dnl For programs that must use an ANSI compiler, obtain compiler options that
 417 dnl will make it recognize prototypes.  We'll do preprocessor checks in other
 418 dnl macros, since tools such as unproto can fake prototypes, but only part of
 419 dnl the preprocessor.
 420 AC_DEFUN([CF_ANSI_CC_REQD],
 421 [AC_REQUIRE([CF_ANSI_CC_CHECK])
 422 if test "$cf_cv_ansi_cc" = "no"; then
 423         AC_MSG_ERROR(
 424 [Your compiler does not appear to recognize prototypes.
 425 You have the following choices:
 426         a. adjust your compiler options
 427         b. get an up-to-date compiler
 428         c. use a wrapper such as unproto])
 429 fi
 430 ])dnl
 431 dnl ---------------------------------------------------------------------------
 432 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 433 dnl --------------
 434 dnl Allow user to disable a normally-on option.
 435 AC_DEFUN([CF_ARG_DISABLE],
 436 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 437 dnl ---------------------------------------------------------------------------
 438 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 439 dnl -------------
 440 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 441 dnl values.
 442 dnl
 443 dnl Parameters:
 444 dnl $1 = option name
 445 dnl $2 = help-string
 446 dnl $3 = action to perform if option is not default
 447 dnl $4 = action if perform if option is default
 448 dnl $5 = default option value (either 'yes' or 'no')
 449 AC_DEFUN([CF_ARG_OPTION],
 450 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 451   if test "$enableval" != "$5" ; then
 452 ifelse([$3],,[    :]dnl
 453 ,[    $3]) ifelse([$4],,,[
 454   else
 455     $4])
 456   fi],[enableval=$5 ifelse([$4],,,[
 457   $4
 458 ])dnl
 459   ])])dnl
 460 dnl ---------------------------------------------------------------------------
 461 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 462 dnl -----------
 463 dnl Check for suitable "ar" (archiver) options for updating an archive.
 464 AC_DEFUN([CF_AR_FLAGS],[
 465 AC_REQUIRE([CF_PROG_AR])
 466
 467 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 468         cf_cv_ar_flags=unknown
 469         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 470         do
 471
 472                 # check if $ARFLAGS already contains this choice
 473                 if test "x$ARFLAGS" != "x" ; then
 474                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 475                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 476                                 cf_cv_ar_flags=
 477                                 break
 478                         fi
 479                 fi
 480
 481                 rm -f conftest.$ac_cv_objext
 482                 rm -f conftest.a
 483
 484                 cat >conftest.$ac_ext <<EOF
 485 #line __oline__ "configure"
 486 int     testdata[[3]] = { 123, 456, 789 };
 487 EOF
 488                 if AC_TRY_EVAL(ac_compile) ; then
 489                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 490                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 491                         if test -f conftest.a ; then
 492                                 cf_cv_ar_flags=$cf_ar_flags
 493                                 break
 494                         fi
 495                 else
 496                         CF_VERBOSE(cannot compile test-program)
 497                         break
 498                 fi
 499         done
 500         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 501 ])
 502
 503 if test -n "$ARFLAGS" ; then
 504         if test -n "$cf_cv_ar_flags" ; then
 505                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 506         fi
 507 else
 508         ARFLAGS=$cf_cv_ar_flags
 509 fi
 510
 511 AC_SUBST(ARFLAGS)
 512 ])
 513 dnl ---------------------------------------------------------------------------
 514 dnl CF_AWK_BIG_PRINTF version: 4 updated: 2011/10/30 17:09:50
 515 dnl -----------------
 516 dnl Check if awk can handle big strings using printf.  Some older versions of
 517 dnl awk choke on large strings passed via "%s".
 518 dnl
 519 dnl $1 = desired string size
 520 dnl $2 = variable to set with result
 521 AC_DEFUN([CF_AWK_BIG_PRINTF],
 522 [
 523         case x$AWK in #(vi
 524         x)
 525                 eval $2=no
 526                 ;;
 527         *) #(vi
 528                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 529                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 530                         eval $2=yes
 531                 else
 532                         eval $2=no
 533                 fi
 534                 ;;
 535         esac
 536 ])dnl
 537 dnl ---------------------------------------------------------------------------
 538 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 539 dnl ------------
 540 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 541 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 542 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 543 dnl
 544 dnl Treat the configuration-variable specially here, since we're directly
 545 dnl substituting its value (i.e., 1/0).
 546 dnl
 547 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 548 AC_DEFUN([CF_BOOL_DECL],
 549 [
 550 AC_MSG_CHECKING(if we should include stdbool.h)
 551
 552 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 553         AC_TRY_COMPILE([],[bool foo = false],
 554                 [cf_cv_header_stdbool_h=0],
 555                 [AC_TRY_COMPILE([
 556 #ifndef __BEOS__
 557 #include <stdbool.h>
 558 #endif
 559 ],[bool foo = false],
 560                         [cf_cv_header_stdbool_h=1],
 561                         [cf_cv_header_stdbool_h=0])])])
 562
 563 if test "$cf_cv_header_stdbool_h" = 1
 564 then    AC_MSG_RESULT(yes)
 565 else    AC_MSG_RESULT(no)
 566 fi
 567
 568 AC_MSG_CHECKING([for builtin bool type])
 569
 570 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 571         AC_TRY_COMPILE([
 572 #include <stdio.h>
 573 #include <sys/types.h>
 574 ],[bool x = false],
 575                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 576                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 577         ])
 578
 579 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 580 then    AC_MSG_RESULT(yes)
 581 else    AC_MSG_RESULT(no)
 582 fi
 583 ])dnl
 584 dnl ---------------------------------------------------------------------------
 585 dnl CF_BOOL_SIZE version: 12 updated: 2006/12/16 12:33:30
 586 dnl ------------
 587 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 588 dnl Don't bother looking for bool.h, since it's been deprecated.
 589 dnl
 590 dnl If the current compiler is C rather than C++, we get the bool definition
 591 dnl from <stdbool.h>.
 592 AC_DEFUN([CF_BOOL_SIZE],
 593 [
 594 AC_MSG_CHECKING([for size of bool])
 595 AC_CACHE_VAL(cf_cv_type_of_bool,[
 596         rm -f cf_test.out
 597         AC_TRY_RUN([
 598 #include <stdlib.h>
 599 #include <stdio.h>
 600
 601 #if defined(__cplusplus)
 602
 603 #ifdef HAVE_GXX_BUILTIN_H
 604 #include <g++/builtin.h>
 605 #elif HAVE_GPP_BUILTIN_H
 606 #include <gpp/builtin.h>
 607 #elif HAVE_BUILTIN_H
 608 #include <builtin.h>
 609 #endif
 610
 611 #else
 612
 613 #if $cf_cv_header_stdbool_h
 614 #include <stdbool.h>
 615 #endif
 616
 617 #endif
 618
 619 main()
 620 {
 621         FILE *fp = fopen("cf_test.out", "w");
 622         if (fp != 0) {
 623                 bool x = true;
 624                 if ((bool)(-x) >= 0)
 625                         fputs("unsigned ", fp);
 626                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 627                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 628                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 629                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 630                 fclose(fp);
 631         }
 632         ${cf_cv_main_return:-return}(0);
 633 }
 634                 ],
 635                 [cf_cv_type_of_bool=`cat cf_test.out`
 636                  if test -z "$cf_cv_type_of_bool"; then
 637                    cf_cv_type_of_bool=unknown
 638                  fi],
 639                 [cf_cv_type_of_bool=unknown],
 640                 [cf_cv_type_of_bool=unknown])
 641         ])
 642         rm -f cf_test.out
 643 AC_MSG_RESULT($cf_cv_type_of_bool)
 644 if test "$cf_cv_type_of_bool" = unknown ; then
 645         case .$NCURSES_BOOL in #(vi
 646         .auto|.) NCURSES_BOOL=unsigned;;
 647         esac
 648         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 649         cf_cv_type_of_bool=$NCURSES_BOOL
 650 fi
 651 ])dnl
 652 dnl ---------------------------------------------------------------------------
 653 dnl CF_BUILD_CC version: 6 updated: 2006/10/14 15:23:15
 654 dnl -----------
 655 dnl If we're cross-compiling, allow the user to override the tools and their
 656 dnl options.  The configure script is oriented toward identifying the host
 657 dnl compiler, etc., but we need a build compiler to generate parts of the
 658 dnl source.
 659 dnl
 660 dnl $1 = default for $CPPFLAGS
 661 dnl $2 = default for $LIBS
 662 AC_DEFUN([CF_BUILD_CC],[
 663 AC_REQUIRE([CF_PROG_EXT])
 664 if test "$cross_compiling" = yes ; then
 665
 666         # defaults that we might want to override
 667         : ${BUILD_CFLAGS:=''}
 668         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 669         : ${BUILD_LDFLAGS:=''}
 670         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 671         : ${BUILD_EXEEXT:='$x'}
 672         : ${BUILD_OBJEXT:='o'}
 673
 674         AC_ARG_WITH(build-cc,
 675                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 676                 [BUILD_CC="$withval"],
 677                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 678         AC_MSG_CHECKING(for native build C compiler)
 679         AC_MSG_RESULT($BUILD_CC)
 680
 681         AC_MSG_CHECKING(for native build C preprocessor)
 682         AC_ARG_WITH(build-cpp,
 683                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 684                 [BUILD_CPP="$withval"],
 685                 [BUILD_CPP='${BUILD_CC} -E'])
 686         AC_MSG_RESULT($BUILD_CPP)
 687
 688         AC_MSG_CHECKING(for native build C flags)
 689         AC_ARG_WITH(build-cflags,
 690                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 691                 [BUILD_CFLAGS="$withval"])
 692         AC_MSG_RESULT($BUILD_CFLAGS)
 693
 694         AC_MSG_CHECKING(for native build C preprocessor-flags)
 695         AC_ARG_WITH(build-cppflags,
 696                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 697                 [BUILD_CPPFLAGS="$withval"])
 698         AC_MSG_RESULT($BUILD_CPPFLAGS)
 699
 700         AC_MSG_CHECKING(for native build linker-flags)
 701         AC_ARG_WITH(build-ldflags,
 702                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 703                 [BUILD_LDFLAGS="$withval"])
 704         AC_MSG_RESULT($BUILD_LDFLAGS)
 705
 706         AC_MSG_CHECKING(for native build linker-libraries)
 707         AC_ARG_WITH(build-libs,
 708                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 709                 [BUILD_LIBS="$withval"])
 710         AC_MSG_RESULT($BUILD_LIBS)
 711
 712         # this assumes we're on Unix.
 713         BUILD_EXEEXT=
 714         BUILD_OBJEXT=o
 715
 716         : ${BUILD_CC:='${CC}'}
 717
 718         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 719                 AC_MSG_ERROR([Cross-build requires two compilers.
 720 Use --with-build-cc to specify the native compiler.])
 721         fi
 722
 723 else
 724         : ${BUILD_CC:='${CC}'}
 725         : ${BUILD_CPP:='${CPP}'}
 726         : ${BUILD_CFLAGS:='${CFLAGS}'}
 727         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 728         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 729         : ${BUILD_LIBS:='${LIBS}'}
 730         : ${BUILD_EXEEXT:='$x'}
 731         : ${BUILD_OBJEXT:='o'}
 732 fi
 733
 734 AC_SUBST(BUILD_CC)
 735 AC_SUBST(BUILD_CPP)
 736 AC_SUBST(BUILD_CFLAGS)
 737 AC_SUBST(BUILD_CPPFLAGS)
 738 AC_SUBST(BUILD_LDFLAGS)
 739 AC_SUBST(BUILD_LIBS)
 740 AC_SUBST(BUILD_EXEEXT)
 741 AC_SUBST(BUILD_OBJEXT)
 742 ])dnl
 743 dnl ---------------------------------------------------------------------------
 744 dnl CF_CFG_DEFAULTS version: 8 updated: 2011/06/04 20:09:13
 745 dnl ---------------
 746 dnl Determine the default configuration into which we'll install ncurses.  This
 747 dnl can be overridden by the user's command-line options.  There's two items to
 748 dnl look for:
 749 dnl     1. the prefix (e.g., /usr)
 750 dnl     2. the header files (e.g., /usr/include/ncurses)
 751 dnl We'll look for a previous installation of ncurses and use the same defaults.
 752 dnl
 753 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 754 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 755 dnl programs from a vendor's.
 756 AC_DEFUN([CF_CFG_DEFAULTS],
 757 [
 758 AC_MSG_CHECKING(for prefix)
 759 if test "x$prefix" = "xNONE" ; then
 760         case "$cf_cv_system_name" in
 761                 # non-vendor systems don't have a conflict
 762         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|k*bsd*-gnu)
 763                 prefix=/usr
 764                 ;;
 765         *)      prefix=$ac_default_prefix
 766                 ;;
 767         esac
 768 fi
 769 AC_MSG_RESULT($prefix)
 770
 771 if test "x$prefix" = "xNONE" ; then
 772 AC_MSG_CHECKING(for default include-directory)
 773 test -n "$verbose" && echo 1>&AC_FD_MSG
 774 for cf_symbol in \
 775         $includedir \
 776         $includedir/ncurses \
 777         $prefix/include \
 778         $prefix/include/ncurses \
 779         /usr/local/include \
 780         /usr/local/include/ncurses \
 781         /usr/include \
 782         /usr/include/ncurses
 783 do
 784         cf_dir=`eval echo $cf_symbol`
 785         if test -f $cf_dir/curses.h ; then
 786         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 787                 includedir="$cf_symbol"
 788                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 789                 break
 790         fi
 791         fi
 792         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 793 done
 794 AC_MSG_RESULT($includedir)
 795 fi
 796 ])dnl
 797 dnl ---------------------------------------------------------------------------
 798 dnl CF_CGETENT version: 4 updated: 2011/08/07 14:54:41
 799 dnl ----------
 800 dnl Check if the terminal-capability database functions are available.  If not,
 801 dnl ncurses has a much-reduced version.
 802 AC_DEFUN([CF_CGETENT],[
 803 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 804 AC_TRY_LINK([
 805 #include <stdlib.h>],[
 806         char temp[128];
 807         char *buf = temp;
 808         char *db_array = temp;
 809         cgetent(&buf, &db_array, "vt100");
 810         cgetcap(buf, "tc", '=');
 811         cgetmatch(buf, "tc");
 812         ],
 813         [cf_cv_cgetent=yes],
 814         [cf_cv_cgetent=no])
 815 ])
 816
 817 if test "$cf_cv_cgetent" = yes
 818 then
 819         AC_DEFINE(HAVE_BSD_CGETENT)
 820 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 821 AC_TRY_LINK([
 822 #include <stdlib.h>],[
 823         char temp[128];
 824         char *buf = temp;
 825 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 826         const char *db_array = temp;
 827         cgetent(&buf, &db_array, "vt100");
 828 #endif
 829         cgetcap(buf, "tc", '=');
 830         cgetmatch(buf, "tc");
 831         ],
 832         [cf_cv_cgetent_const=yes],
 833         [cf_cv_cgetent_const=no])
 834 ])
 835         if test "$cf_cv_cgetent_const" = yes
 836         then
 837                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const)
 838         fi
 839 fi
 840 ])dnl
 841 dnl ---------------------------------------------------------------------------
 842 dnl CF_CHECK_CACHE version: 11 updated: 2008/03/23 14:45:59
 843 dnl --------------
 844 dnl Check if we're accidentally using a cache from a different machine.
 845 dnl Derive the system name, as a check for reusing the autoconf cache.
 846 dnl
 847 dnl If we've packaged config.guess and config.sub, run that (since it does a
 848 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 849 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 850 dnl which is useful in cross-compiles.
 851 dnl
 852 dnl Note: we would use $ac_config_sub, but that is one of the places where
 853 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 854 AC_DEFUN([CF_CHECK_CACHE],
 855 [
 856 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 857         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 858         system_name="$host_os"
 859 else
 860         system_name="`(uname -s -r) 2>/dev/null`"
 861         if test -z "$system_name" ; then
 862                 system_name="`(hostname) 2>/dev/null`"
 863         fi
 864 fi
 865 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name")
 866 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 867
 868 test -z "$system_name" && system_name="$cf_cv_system_name"
 869 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 870
 871 if test ".$system_name" != ".$cf_cv_system_name" ; then
 872         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 873         AC_MSG_ERROR("Please remove config.cache and try again.")
 874 fi
 875 ])dnl
 876 dnl ---------------------------------------------------------------------------
 877 dnl CF_CHECK_ERRNO version: 11 updated: 2010/05/26 05:38:42
 878 dnl --------------
 879 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 880 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 881 dnl ourselves.
 882 dnl
 883 dnl $1 = the name to check
 884 dnl $2 = the assumed type
 885 AC_DEFUN([CF_CHECK_ERRNO],
 886 [
 887 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 888     AC_TRY_COMPILE([
 889 #ifdef HAVE_STDLIB_H
 890 #include <stdlib.h>
 891 #endif
 892 #include <stdio.h>
 893 #include <sys/types.h>
 894 #include <errno.h> ],
 895     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 896     [cf_cv_dcl_$1=yes],
 897     [cf_cv_dcl_$1=no])
 898 ])
 899
 900 if test "$cf_cv_dcl_$1" = no ; then
 901     CF_UPPER(cf_result,decl_$1)
 902     AC_DEFINE_UNQUOTED($cf_result)
 903 fi
 904
 905 # It's possible (for near-UNIX clones) that the data doesn't exist
 906 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 907 ])dnl
 908 dnl ---------------------------------------------------------------------------
 909 dnl CF_CHECK_EXTERN_DATA version: 3 updated: 2001/12/30 18:03:23
 910 dnl --------------------
 911 dnl Check for existence of external data in the current set of libraries.  If
 912 dnl we can modify it, it's real enough.
 913 dnl $1 = the name to check
 914 dnl $2 = its type
 915 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 916 [
 917 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 918     AC_TRY_LINK([
 919 #undef $1
 920 extern $2 $1;
 921 ],
 922     [$1 = 2],
 923     [cf_cv_have_$1=yes],
 924     [cf_cv_have_$1=no])
 925 ])
 926
 927 if test "$cf_cv_have_$1" = yes ; then
 928     CF_UPPER(cf_result,have_$1)
 929     AC_DEFINE_UNQUOTED($cf_result)
 930 fi
 931
 932 ])dnl
 933 dnl ---------------------------------------------------------------------------
 934 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 935 dnl -------------------
 936 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 937 dnl is not "weak" - warn about this because it can create problems linking
 938 dnl applications with ncurses.
 939 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 940 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 941
 942 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 943 cf_cv_check_gpm_wgetch=unknown
 944 if test "$cross_compiling" != yes ; then
 945
 946 cat >conftest.$ac_ext <<CF_EOF
 947 #include <gpm.h>
 948 int main()
 949 {
 950         Gpm_Wgetch();
 951         ${cf_cv_main_return:-return}(0);
 952 }
 953 CF_EOF
 954
 955         cf_save_LIBS="$LIBS"
 956         # This only works if we can look at the symbol table.  If a shared
 957         # library is stripped for install, we cannot use that.  So we're forced
 958         # to rely on the static library, noting that some packagers may not
 959         # include it.
 960         LIBS="-static -lgpm -dynamic $LIBS"
 961         if AC_TRY_EVAL(ac_compile) ; then
 962                 if AC_TRY_EVAL(ac_link) ; then
 963                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 964                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 965                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 966                 fi
 967         fi
 968         rm -rf conftest*
 969         LIBS="$cf_save_LIBS"
 970 fi
 971 ])
 972
 973 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 974         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 975 fi
 976 ])])dnl
 977 dnl ---------------------------------------------------------------------------
 978 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
 979 dnl ----------------
 980 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
 981 AC_DEFUN([CF_CHECK_WCHAR_H],[
 982 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
 983 AC_TRY_COMPILE(
 984 [
 985 #include <stdlib.h>
 986 #include <wchar.h>
 987 ],[
 988         wint_t foo = 0;
 989         int bar = iswpunct(foo)],
 990         [cf_cv_wchar_h_okay=yes],
 991         [cf_cv_wchar_h_okay=no])])
 992
 993 if test $cf_cv_wchar_h_okay = no
 994 then
 995         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 996 fi
 997 ])dnl
 998 dnl ---------------------------------------------------------------------------
 999 dnl CF_CPP_PARAM_INIT version: 5 updated: 2011/12/03 16:54:03
1000 dnl -----------------
1001 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1002 dnl is a late feature for the standard and is not in some recent compilers
1003 dnl (1999/9/11).
1004 AC_DEFUN([CF_CPP_PARAM_INIT],
1005 [
1006 if test -n "$CXX"; then
1007 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1008         AC_LANG_SAVE
1009         AC_LANG_CPLUSPLUS
1010         AC_TRY_RUN([
1011 class TEST {
1012 private:
1013         int value;
1014 public:
1015         TEST(int x = 1);
1016         ~TEST();
1017 };
1018
1019 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1020 {
1021         value = x;
1022 }
1023 int main() { }
1024 ],
1025         [cf_cv_cpp_param_init=yes],
1026         [cf_cv_cpp_param_init=no],
1027         [cf_cv_cpp_param_init=unknown])
1028         AC_LANG_RESTORE
1029 ])
1030 fi
1031 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT)
1032 ])dnl
1033 dnl ---------------------------------------------------------------------------
1034 dnl CF_CPP_STATIC_CAST version: 1 updated: 2005/07/23 16:52:43
1035 dnl ------------------
1036 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1037 dnl not be supported in g++ before 3.0
1038 AC_DEFUN([CF_CPP_STATIC_CAST],
1039 [
1040 if test -n "$CXX"; then
1041
1042 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1043         AC_LANG_SAVE
1044         AC_LANG_CPLUSPLUS
1045
1046         AC_TRY_COMPILE([
1047 class NCursesPanel
1048 {
1049 public:
1050   NCursesPanel(int nlines,
1051                int ncols,
1052                int begin_y = 0,
1053                int begin_x = 0)
1054   {
1055   }
1056
1057   ~NCursesPanel();
1058 };
1059
1060 template<class T> class NCursesUserPanel : public NCursesPanel
1061 {
1062 public:
1063   NCursesUserPanel (int nlines,
1064                     int ncols,
1065                     int begin_y = 0,
1066                     int begin_x = 0,
1067                     const T* p_UserData = static_cast<T*>(0))
1068     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1069   {
1070   };
1071   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1072   {
1073   };
1074
1075   virtual ~NCursesUserPanel() {};
1076 };
1077 ],[
1078         const char* p_UserData = static_cast<char*>(0)],
1079         [cf_cv_cpp_static_cast=yes],
1080         [cf_cv_cpp_static_cast=no])
1081
1082         AC_LANG_RESTORE
1083 ])
1084
1085 fi
1086
1087 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST)
1088 ])dnl
1089 dnl ---------------------------------------------------------------------------
1090 dnl CF_CXX_AR_FLAGS version: 1 updated: 2011/10/29 08:35:34
1091 dnl ---------------
1092 dnl Setup special archiver flags for given compilers.
1093 AC_DEFUN([CF_CXX_AR_FLAGS],[
1094         CXX_AR='$(AR)'
1095         CXX_ARFLAGS='$(ARFLAGS)'
1096         case $cf_cv_system_name in #(vi
1097         irix*) #(vi
1098             if test "$GXX" != yes ; then
1099                 CXX_AR='$(CXX)'
1100                 CXX_ARFLAGS='-ar -o'
1101             fi
1102             ;;
1103         sco3.2v5*) #(vi
1104             CXXLDFLAGS="-u main"
1105             ;;
1106         solaris2*)
1107             if test "$GXX" != yes ; then
1108                 CXX_AR='$(CXX)'
1109                 CXX_ARFLAGS='-xar -o'
1110             fi
1111             ;;
1112         esac
1113         AC_SUBST(CXXLDFLAGS)
1114         AC_SUBST(CXX_AR)
1115         AC_SUBST(CXX_ARFLAGS)
1116 ])dnl
1117 dnl ---------------------------------------------------------------------------
1118 dnl CF_CXX_IOSTREAM_NAMESPACE version: 1 updated: 2011/10/29 08:35:34
1119 dnl -------------------------
1120 dnl For c++, check if iostream uses "std::" namespace.
1121 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1122 AC_CHECK_HEADERS(iostream)
1123 if test x"$ac_cv_header_iostream" = xyes ; then
1124         AC_MSG_CHECKING(if iostream uses std-namespace)
1125         AC_TRY_COMPILE([
1126 #include <iostream>
1127 using std::endl;
1128 using std::cerr;],[
1129 cerr << "testing" << endl;
1130 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1131         AC_MSG_RESULT($cf_iostream_namespace)
1132         if test "$cf_iostream_namespace" = yes ; then
1133                 AC_DEFINE(IOSTREAM_NAMESPACE)
1134         fi
1135 fi
1136 ])dnl
1137 dnl ---------------------------------------------------------------------------
1138 dnl CF_C_INLINE version: 3 updated: 2010/05/01 15:14:41
1139 dnl -----------
1140 dnl Check if the C compiler supports "inline".
1141 dnl $1 is the name of a shell variable to set if inline is supported
1142 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1143 AC_DEFUN([CF_C_INLINE],[
1144 AC_C_INLINE
1145 $1=
1146 if test "$ac_cv_c_inline" != no ; then
1147   $1=inline
1148   if test "$INTEL_COMPILER" = yes
1149   then
1150     :
1151   elif test "$GCC" = yes
1152   then
1153     AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1154       cf_save_CFLAGS=$CFLAGS
1155       CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1156       AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1157       [${cf_cv_main_return:-return} foo()],
1158       [cf_cv_gcc_inline=yes],
1159       [cf_cv_gcc_inline=no])
1160       CFLAGS=$cf_save_CFLAGS
1161     ])
1162     if test "$cf_cv_gcc_inline" = yes ; then
1163         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1164     fi
1165   fi
1166 fi
1167 AC_SUBST($1)
1168 ])dnl
1169 dnl ---------------------------------------------------------------------------
1170 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1171 dnl ----------
1172 dnl "dirname" is not portable, so we fake it with a shell script.
1173 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1174 dnl ---------------------------------------------------------------------------
1175 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1176 dnl ---------------
1177 AC_DEFUN([CF_DIRS_TO_MAKE],
1178 [
1179 DIRS_TO_MAKE="lib"
1180 for cf_item in $cf_list_models
1181 do
1182         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1183         for cf_item2 in $DIRS_TO_MAKE
1184         do
1185                 test $cf_item2 = $cf_subdir && break
1186         done
1187         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1188 done
1189 for cf_dir in $DIRS_TO_MAKE
1190 do
1191         test ! -d $cf_dir && mkdir $cf_dir
1192 done
1193 AC_SUBST(DIRS_TO_MAKE)
1194 ])dnl
1195 dnl ---------------------------------------------------------------------------
1196 dnl CF_DISABLE_LEAKS version: 6 updated: 2010/07/23 04:14:32
1197 dnl ----------------
1198 dnl Combine no-leak checks with the libraries or tools that are used for the
1199 dnl checks.
1200 AC_DEFUN([CF_DISABLE_LEAKS],[
1201
1202 AC_REQUIRE([CF_WITH_DMALLOC])
1203 AC_REQUIRE([CF_WITH_DBMALLOC])
1204 AC_REQUIRE([CF_WITH_VALGRIND])
1205
1206 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1207 AC_ARG_ENABLE(leaks,
1208         [  --disable-leaks         test: free permanent memory, analyze leaks],
1209         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1210         : ${with_no_leaks:=no})
1211 AC_MSG_RESULT($with_no_leaks)
1212
1213 if test "$with_no_leaks" = yes ; then
1214         AC_DEFINE(NO_LEAKS)
1215         AC_DEFINE(YY_NO_LEAKS)
1216 fi
1217 ])dnl
1218 dnl ---------------------------------------------------------------------------
1219 dnl CF_DISABLE_LIBTOOL_VERSION version: 1 updated: 2010/05/15 15:45:59
1220 dnl --------------------------
1221 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1222 dnl the older "-version-info" feature.  The newer feature allows us to use
1223 dnl version numbering on shared libraries which make them compatible with
1224 dnl various systems.
1225 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1226 [
1227 AC_MSG_CHECKING(if libtool -version-number should be used)
1228 CF_ARG_DISABLE(libtool-version,
1229         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1230         [cf_libtool_version=no],
1231         [cf_libtool_version=yes])
1232 AC_MSG_RESULT($cf_libtool_version)
1233
1234 if test "$cf_libtool_version" = yes ; then
1235         LIBTOOL_VERSION="-version-number"
1236 else
1237         LIBTOOL_VERSION="-version-info"
1238 fi
1239
1240 AC_SUBST(LIBTOOL_VERSION)
1241 ])dnl
1242 dnl ---------------------------------------------------------------------------
1243 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1244 dnl ---------------------
1245 dnl The rpath-hack makes it simpler to build programs, particularly with the
1246 dnl *BSD ports which may have essential libraries in unusual places.  But it
1247 dnl can interfere with building an executable for the base system.  Use this
1248 dnl option in that case.
1249 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1250 [
1251 AC_MSG_CHECKING(if rpath-hack should be disabled)
1252 CF_ARG_DISABLE(rpath-hack,
1253         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1254         [cf_disable_rpath_hack=yes],
1255         [cf_disable_rpath_hack=no])
1256 AC_MSG_RESULT($cf_disable_rpath_hack)
1257 if test "$cf_disable_rpath_hack" = no ; then
1258         CF_RPATH_HACK
1259 fi
1260 ])
1261 dnl ---------------------------------------------------------------------------
1262 dnl CF_ENABLE_PC_FILES version: 7 updated: 2011/12/10 18:58:47
1263 dnl ------------------
1264 dnl This is the "--enable-pc-files" option, which is available if there is a
1265 dnl pkg-config configuration on the local machine.
1266 AC_DEFUN([CF_ENABLE_PC_FILES],[
1267 AC_REQUIRE([CF_PKG_CONFIG])
1268 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1269
1270 if test "$PKG_CONFIG" != none ; then
1271         if test -n "$PKG_CONFIG_LIBDIR" && test -d "$PKG_CONFIG_LIBDIR" ; then
1272                 AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1273                 AC_ARG_ENABLE(pc-files,
1274                         [  --enable-pc-files       generate and install .pc files for pkg-config],
1275                         [enable_pc_files=$enableval],
1276                         [enable_pc_files=no])
1277                 AC_MSG_RESULT($enable_pc_files)
1278         elif test -z "$PKG_CONFIG_LIBDIR" || test "$PKG_CONFIG_LIBDIR" != no; then
1279                 enable_pc_files=no
1280                 AC_MSG_WARN(did not find $PKG_CONFIG library)
1281         fi
1282 else
1283         enable_pc_files=no
1284 fi
1285 ])dnl
1286 dnl ---------------------------------------------------------------------------
1287 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1288 dnl ---------------
1289 dnl Check if the rpath option should be used, setting cache variable
1290 dnl cf_cv_enable_rpath if so.
1291 AC_DEFUN([CF_ENABLE_RPATH],
1292 [
1293 AC_MSG_CHECKING(if rpath option should be used)
1294 AC_ARG_ENABLE(rpath,
1295 [  --enable-rpath          use rpath option when generating shared libraries],
1296 [cf_cv_enable_rpath=$enableval],
1297 [cf_cv_enable_rpath=no])
1298 AC_MSG_RESULT($cf_cv_enable_rpath)
1299 ])dnl
1300 dnl ---------------------------------------------------------------------------
1301 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1302 dnl --------
1303 dnl Check if 'errno' is declared in <errno.h>
1304 AC_DEFUN([CF_ERRNO],
1305 [
1306 CF_CHECK_ERRNO(errno)
1307 ])dnl
1308 dnl ---------------------------------------------------------------------------
1309 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1310 dnl ---------------
1311 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1312 dnl math.h and builtin.h, only for ncurses
1313 AC_DEFUN([CF_ETIP_DEFINES],
1314 [
1315 AC_MSG_CHECKING(for special defines needed for etip.h)
1316 cf_save_CXXFLAGS="$CXXFLAGS"
1317 cf_result="none"
1318
1319 # etip.h includes ncurses.h which includes ncurses_dll.h
1320 # But ncurses_dll.h is generated - fix here.
1321 test -d include || mkdir include
1322 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1323
1324 for cf_math in "" MATH_H
1325 do
1326 for cf_excp in "" MATH_EXCEPTION
1327 do
1328         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1329         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1330         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1331 AC_TRY_COMPILE([
1332 #include <etip.h.in>
1333 ],[],[
1334         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1335         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1336         cf_result="$cf_math $cf_excp"
1337         break 2
1338 ],[])
1339 done
1340 done
1341 AC_MSG_RESULT($cf_result)
1342 CXXFLAGS="$cf_save_CXXFLAGS"
1343 ])
1344 dnl ---------------------------------------------------------------------------
1345 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1346 dnl ---------------
1347 dnl Find a library (specifically the linkage used in the code fragment),
1348 dnl searching for it if it is not already in the library path.
1349 dnl See also CF_ADD_SEARCHPATH.
1350 dnl
1351 dnl Parameters (4-on are optional):
1352 dnl     $1 = headers for library entrypoint
1353 dnl     $2 = code fragment for library entrypoint
1354 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1355 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1356 dnl     $5 = action to perform if not successful
1357 dnl     $6 = module name, if not the same as the library name
1358 dnl     $7 = extra libraries
1359 dnl
1360 dnl Sets these variables:
1361 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1362 dnl     $cf_cv_header_path_$3 - include-directory if needed
1363 dnl     $cf_cv_library_path_$3 - library-directory if needed
1364 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1365 AC_DEFUN([CF_FIND_LINKAGE],[
1366
1367 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1368 # will be set on completion of the AC_TRY_LINK below.
1369 cf_cv_header_path_$3=
1370 cf_cv_library_path_$3=
1371
1372 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1373
1374 cf_save_LIBS="$LIBS"
1375
1376 AC_TRY_LINK([$1],[$2],[
1377         cf_cv_find_linkage_$3=yes
1378         cf_cv_header_path_$3=/usr/include
1379         cf_cv_library_path_$3=/usr/lib
1380 ],[
1381
1382 LIBS="-l$3 $7 $cf_save_LIBS"
1383
1384 AC_TRY_LINK([$1],[$2],[
1385         cf_cv_find_linkage_$3=yes
1386         cf_cv_header_path_$3=/usr/include
1387         cf_cv_library_path_$3=/usr/lib
1388         cf_cv_library_file_$3="-l$3"
1389 ],[
1390         cf_cv_find_linkage_$3=no
1391         LIBS="$cf_save_LIBS"
1392
1393     CF_VERBOSE(find linkage for $3 library)
1394     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1395
1396     cf_save_CPPFLAGS="$CPPFLAGS"
1397     cf_test_CPPFLAGS="$CPPFLAGS"
1398
1399     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1400     for cf_cv_header_path_$3 in $cf_search
1401     do
1402       if test -d $cf_cv_header_path_$3 ; then
1403         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1404         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1405         AC_TRY_COMPILE([$1],[$2],[
1406             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1407             cf_cv_find_linkage_$3=maybe
1408             cf_test_CPPFLAGS="$CPPFLAGS"
1409             break],[
1410             CPPFLAGS="$cf_save_CPPFLAGS"
1411             ])
1412       fi
1413     done
1414
1415     if test "$cf_cv_find_linkage_$3" = maybe ; then
1416
1417       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1418
1419       cf_save_LIBS="$LIBS"
1420       cf_save_LDFLAGS="$LDFLAGS"
1421
1422       ifelse([$6],,,[
1423         CPPFLAGS="$cf_test_CPPFLAGS"
1424         LIBS="-l$3 $7 $cf_save_LIBS"
1425         AC_TRY_LINK([$1],[$2],[
1426             CF_VERBOSE(... found $3 library in system)
1427             cf_cv_find_linkage_$3=yes])
1428             CPPFLAGS="$cf_save_CPPFLAGS"
1429             LIBS="$cf_save_LIBS"
1430             ])
1431
1432       if test "$cf_cv_find_linkage_$3" != yes ; then
1433         CF_LIBRARY_PATH(cf_search,$3)
1434         for cf_cv_library_path_$3 in $cf_search
1435         do
1436           if test -d $cf_cv_library_path_$3 ; then
1437             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1438             CPPFLAGS="$cf_test_CPPFLAGS"
1439             LIBS="-l$3 $7 $cf_save_LIBS"
1440             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1441             AC_TRY_LINK([$1],[$2],[
1442                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1443                 cf_cv_find_linkage_$3=yes
1444                 cf_cv_library_file_$3="-l$3"
1445                 break],[
1446                 CPPFLAGS="$cf_save_CPPFLAGS"
1447                 LIBS="$cf_save_LIBS"
1448                 LDFLAGS="$cf_save_LDFLAGS"
1449                 ])
1450           fi
1451         done
1452         CPPFLAGS="$cf_save_CPPFLAGS"
1453         LDFLAGS="$cf_save_LDFLAGS"
1454       fi
1455
1456     else
1457       cf_cv_find_linkage_$3=no
1458     fi
1459     ],$7)
1460 ])
1461
1462 LIBS="$cf_save_LIBS"
1463
1464 if test "$cf_cv_find_linkage_$3" = yes ; then
1465 ifelse([$4],,[
1466         CF_ADD_INCDIR($cf_cv_header_path_$3)
1467         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1468         CF_ADD_LIB($3)
1469 ],[$4])
1470 else
1471 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1472 fi
1473 ])dnl
1474 dnl ---------------------------------------------------------------------------
1475 dnl CF_FUNC_DLSYM version: 2 updated: 2010/05/29 16:31:02
1476 dnl -------------
1477 dnl Test for dlsym() and related functions, as well as libdl.
1478 dnl
1479 dnl Sets
1480 dnl     $cf_have_dlsym
1481 dnl     $cf_have_libdl
1482 AC_DEFUN([CF_FUNC_DLSYM],[
1483 cf_have_dlsym=no
1484 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1485
1486 cf_have_libdl=no
1487 AC_CHECK_LIB(dl,dlsym,[
1488         cf_have_dlsym=yes
1489         cf_have_libdl=yes])])
1490
1491 if test "$cf_have_dlsym" = yes ; then
1492         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1493
1494         AC_MSG_CHECKING(whether able to link to dl*() functions)
1495         AC_TRY_LINK([#include <dlfcn.h>],[
1496                 void *obj;
1497                 if ((obj = dlopen("filename", 0)) != 0) {
1498                         if (dlsym(obj, "symbolname") == 0) {
1499                         dlclose(obj);
1500                         }
1501                 }],[
1502                 AC_DEFINE(HAVE_LIBDL)],[
1503                 AC_MSG_ERROR(Cannot link test program for libdl)])
1504         AC_MSG_RESULT(ok)
1505 else
1506         AC_MSG_ERROR(Cannot find dlsym function)
1507 fi
1508 ])
1509 dnl ---------------------------------------------------------------------------
1510 dnl CF_FUNC_MEMMOVE version: 7 updated: 2006/12/16 12:33:30
1511 dnl ---------------
1512 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1513 dnl is found, add our own version of memmove to the list of objects.
1514 AC_DEFUN([CF_FUNC_MEMMOVE],
1515 [
1516 AC_CHECK_FUNC(memmove,,[
1517 AC_CHECK_FUNC(bcopy,[
1518         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1519                 AC_TRY_RUN([
1520 int main() {
1521         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1522         char temp[40];
1523         bcopy(data, temp, sizeof(data));
1524         bcopy(temp+10, temp, 15);
1525         bcopy(temp+5, temp+15, 10);
1526         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1527 }
1528                 ],
1529                 [cf_cv_good_bcopy=yes],
1530                 [cf_cv_good_bcopy=no],
1531                 [cf_cv_good_bcopy=unknown])
1532                 ])
1533         ],[cf_cv_good_bcopy=no])
1534         if test "$cf_cv_good_bcopy" = yes ; then
1535                 AC_DEFINE(USE_OK_BCOPY)
1536         else
1537                 AC_DEFINE(USE_MY_MEMMOVE)
1538         fi
1539 ])])dnl
1540 dnl ---------------------------------------------------------------------------
1541 dnl CF_FUNC_NANOSLEEP version: 3 updated: 2006/12/16 12:33:30
1542 dnl -----------------
1543 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1544 dnl AIX 4.x, provide a non-working version.
1545 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1546 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1547 AC_TRY_RUN([
1548 #include <stdio.h>
1549 #include <errno.h>
1550 #include <time.h>
1551
1552 #ifdef HAVE_SYS_TIME_H
1553 #include <sys/time.h>
1554 #endif
1555
1556 int main() {
1557         struct timespec ts1, ts2;
1558         int code;
1559         ts1.tv_sec  = 0;
1560         ts1.tv_nsec = 750000000;
1561         ts2.tv_sec  = 0;
1562         ts2.tv_nsec = 0;
1563         errno = 0;
1564         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1565         ${cf_cv_main_return:-return}(code != 0);
1566 }
1567 ],
1568         [cf_cv_func_nanosleep=yes],
1569         [cf_cv_func_nanosleep=no],
1570         [cf_cv_func_nanosleep=unknown])])
1571
1572 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP)
1573 ])
1574 dnl ---------------------------------------------------------------------------
1575 dnl CF_FUNC_OPENPTY version: 3 updated: 2010/05/29 16:31:02
1576 dnl ---------------
1577 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1578 dnl "util" library as well.
1579 AC_DEFUN([CF_FUNC_OPENPTY],
1580 [
1581 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1582 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1583     cf_save_LIBS="$LIBS"
1584     test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1585     for cf_header in pty.h libutil.h util.h
1586     do
1587     AC_TRY_LINK([
1588 #include <$cf_header>
1589 ],[
1590     int x = openpty((int *)0, (int *)0, (char *)0,
1591                    (struct termios *)0, (struct winsize *)0);
1592 ],[
1593         cf_cv_func_openpty=$cf_header
1594         break
1595 ],[
1596         cf_cv_func_openpty=no
1597 ])
1598     done
1599     LIBS="$cf_save_LIBS"
1600 ])
1601 ])dnl
1602 dnl ---------------------------------------------------------------------------
1603 dnl CF_FUNC_POLL version: 5 updated: 2012/01/25 17:55:38
1604 dnl ------------
1605 dnl See if the poll function really works.  Some platforms have poll(), but
1606 dnl it does not work for terminals or files.
1607 AC_DEFUN([CF_FUNC_POLL],[
1608 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1609 AC_TRY_RUN([
1610 #include <stdio.h>
1611 #ifdef HAVE_POLL_H
1612 #include <poll.h>
1613 #else
1614 #include <sys/poll.h>
1615 #endif
1616 int main() {
1617         struct pollfd myfds;
1618         int ret;
1619
1620         /* check for Darwin bug with respect to "devices" */
1621         myfds.fd = open("/dev/null", 1);
1622         if (myfds.fd < 0)
1623                 myfds.fd = 0;
1624         myfds.events = POLLIN;
1625         myfds.revents = 0;
1626
1627         ret = poll(&myfds, 1, 100);
1628
1629         if (ret < 0 || (myfds.revents & POLLNVAL)) {
1630                 ret = -1;
1631         } else {
1632
1633                 /* also check with standard input */
1634                 myfds.fd = 0;
1635                 myfds.events = POLLIN;
1636                 myfds.revents = 0;
1637
1638                 ret = poll(&myfds, 1, 100);
1639                 if (ret < 0) {
1640                         ret = 0;
1641                 }
1642         }
1643         ${cf_cv_main_return:-return}(ret != 0);
1644 }],
1645         [cf_cv_working_poll=yes],
1646         [cf_cv_working_poll=no],
1647         [cf_cv_working_poll=unknown])])
1648 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL)
1649 ])dnl
1650 dnl ---------------------------------------------------------------------------
1651 dnl CF_FUNC_TERMIOS version: 2 updated: 2000/07/22 23:37:24
1652 dnl ---------------
1653 dnl Some old/broken variations define tcgetattr() only as a macro in
1654 dnl termio(s).h
1655 AC_DEFUN([CF_FUNC_TERMIOS],[
1656 AC_REQUIRE([CF_STRUCT_TERMIOS])
1657 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1658 AC_TRY_LINK([
1659 #include <sys/types.h>
1660 #ifdef HAVE_UNISTD_H
1661 #include <unistd.h>
1662 #endif
1663 #ifdef HAVE_TERMIOS_H
1664 #include <termios.h>
1665 #define TTY struct termios
1666 #else
1667 #ifdef HAVE_TERMIO_H
1668 #include <termio.h>
1669 #define TTY struct termio
1670 #endif
1671 #endif
1672 ],[
1673 TTY foo;
1674 tcgetattr(1, &foo);],
1675 [cf_cv_have_tcgetattr=yes],
1676 [cf_cv_have_tcgetattr=no])])
1677 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR)
1678 ])dnl
1679 dnl ---------------------------------------------------------------------------
1680 dnl CF_FUNC_VSSCANF version: 3 updated: 2001/12/19 00:50:10
1681 dnl ---------------
1682 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1683 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1684 dnl other functions.
1685 AC_DEFUN([CF_FUNC_VSSCANF],
1686 [
1687 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1688 AC_TRY_LINK([
1689 #include <stdarg.h>
1690 #include <stdio.h>],[
1691         va_list ap;
1692         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1693 AC_TRY_LINK([
1694 #include <stdarg.h>
1695 #include <stdio.h>],[
1696     FILE strbuf;
1697     char *str = "from";
1698
1699     strbuf._flag = _IOREAD;
1700     strbuf._ptr = strbuf._base = (unsigned char *) str;
1701     strbuf._cnt = strlen(str);
1702     strbuf._file = _NFILE;
1703     return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1704 AC_TRY_LINK([
1705 #include <stdarg.h>
1706 #include <stdio.h>],[
1707     FILE strbuf;
1708     char *str = "from";
1709
1710     strbuf._flag = _IOREAD;
1711     strbuf._ptr = strbuf._base = (unsigned char *) str;
1712     strbuf._cnt = strlen(str);
1713     strbuf._file = _NFILE;
1714     return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1715 cf_cv_func_vsscanf=no])])])])
1716
1717 case $cf_cv_func_vsscanf in #(vi
1718 vsscanf) AC_DEFINE(HAVE_VSSCANF);; #(vi
1719 vfscanf) AC_DEFINE(HAVE_VFSCANF);; #(vi
1720 _doscan) AC_DEFINE(HAVE__DOSCAN);;
1721 esac
1722
1723 ])dnl
1724 dnl ---------------------------------------------------------------------------
1725 dnl CF_GCC_ATTRIBUTES version: 14 updated: 2010/10/23 15:52:32
1726 dnl -----------------
1727 dnl Test for availability of useful gcc __attribute__ directives to quiet
1728 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1729 dnl to documentation, unrecognized directives cause older compilers to barf.
1730 AC_DEFUN([CF_GCC_ATTRIBUTES],
1731 [
1732 if test "$GCC" = yes
1733 then
1734 cat > conftest.i <<EOF
1735 #ifndef GCC_PRINTF
1736 #define GCC_PRINTF 0
1737 #endif
1738 #ifndef GCC_SCANF
1739 #define GCC_SCANF 0
1740 #endif
1741 #ifndef GCC_NORETURN
1742 #define GCC_NORETURN /* nothing */
1743 #endif
1744 #ifndef GCC_UNUSED
1745 #define GCC_UNUSED /* nothing */
1746 #endif
1747 EOF
1748 if test "$GCC" = yes
1749 then
1750         AC_CHECKING([for $CC __attribute__ directives])
1751 cat > conftest.$ac_ext <<EOF
1752 #line __oline__ "${as_me:-configure}"
1753 #include "confdefs.h"
1754 #include "conftest.h"
1755 #include "conftest.i"
1756 #if     GCC_PRINTF
1757 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1758 #else
1759 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1760 #endif
1761 #if     GCC_SCANF
1762 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1763 #else
1764 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1765 #endif
1766 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1767 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1768 extern void foo(void) GCC_NORETURN;
1769 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1770 EOF
1771         cf_printf_attribute=no
1772         cf_scanf_attribute=no
1773         for cf_attribute in scanf printf unused noreturn
1774         do
1775                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1776                 cf_directive="__attribute__(($cf_attribute))"
1777                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1778
1779                 case $cf_attribute in #(vi
1780                 printf) #(vi
1781                         cf_printf_attribute=yes
1782                         cat >conftest.h <<EOF
1783 #define GCC_$cf_ATTRIBUTE 1
1784 EOF
1785                         ;;
1786                 scanf) #(vi
1787                         cf_scanf_attribute=yes
1788                         cat >conftest.h <<EOF
1789 #define GCC_$cf_ATTRIBUTE 1
1790 EOF
1791                         ;;
1792                 *) #(vi
1793                         cat >conftest.h <<EOF
1794 #define GCC_$cf_ATTRIBUTE $cf_directive
1795 EOF
1796                         ;;
1797                 esac
1798
1799                 if AC_TRY_EVAL(ac_compile); then
1800                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1801                         cat conftest.h >>confdefs.h
1802                         case $cf_attribute in #(vi
1803                         printf) #(vi
1804                                 if test "$cf_printf_attribute" = no ; then
1805                                         cat >>confdefs.h <<EOF
1806 #define GCC_PRINTFLIKE(fmt,var) /* nothing */
1807 EOF
1808                                 else
1809                                         cat >>confdefs.h <<EOF
1810 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1811 EOF
1812                                 fi
1813                                 ;;
1814                         scanf) #(vi
1815                                 if test "$cf_scanf_attribute" = no ; then
1816                                         cat >>confdefs.h <<EOF
1817 #define GCC_SCANFLIKE(fmt,var) /* nothing */
1818 EOF
1819                                 else
1820                                         cat >>confdefs.h <<EOF
1821 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1822 EOF
1823                                 fi
1824                                 ;;
1825                         esac
1826                 fi
1827         done
1828 else
1829         fgrep define conftest.i >>confdefs.h
1830 fi
1831 rm -rf conftest*
1832 fi
1833 ])dnl
1834 dnl ---------------------------------------------------------------------------
1835 dnl CF_GCC_VERSION version: 5 updated: 2010/04/24 11:02:31
1836 dnl --------------
1837 dnl Find version of gcc
1838 AC_DEFUN([CF_GCC_VERSION],[
1839 AC_REQUIRE([AC_PROG_CC])
1840 GCC_VERSION=none
1841 if test "$GCC" = yes ; then
1842         AC_MSG_CHECKING(version of $CC)
1843         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1844         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1845         AC_MSG_RESULT($GCC_VERSION)
1846 fi
1847 ])dnl
1848 dnl ---------------------------------------------------------------------------
1849 dnl CF_GCC_WARNINGS version: 27 updated: 2010/10/23 15:52:32
1850 dnl ---------------
1851 dnl Check if the compiler supports useful warning options.  There's a few that
1852 dnl we don't use, simply because they're too noisy:
1853 dnl
1854 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1855 dnl     -Wredundant-decls (system headers make this too noisy)
1856 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1857 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1858 dnl             is enabled for ncurses using "--enable-const".
1859 dnl     -pedantic
1860 dnl
1861 dnl Parameter:
1862 dnl     $1 is an optional list of gcc warning flags that a particular
1863 dnl             application might want to use, e.g., "no-unused" for
1864 dnl             -Wno-unused
1865 dnl Special:
1866 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1867 dnl
1868 AC_DEFUN([CF_GCC_WARNINGS],
1869 [
1870 AC_REQUIRE([CF_GCC_VERSION])
1871 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1872
1873 cat > conftest.$ac_ext <<EOF
1874 #line __oline__ "${as_me:-configure}"
1875 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1876 EOF
1877
1878 if test "$INTEL_COMPILER" = yes
1879 then
1880 # The "-wdXXX" options suppress warnings:
1881 # remark #1419: external declaration in primary source file
1882 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1883 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1884 # remark #193: zero used for undefined preprocessing identifier
1885 # remark #593: variable "curs_sb_left_arrow" was set but never used
1886 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1887 # remark #869: parameter "tw" was never referenced
1888 # remark #981: operands are evaluated in unspecified order
1889 # warning #279: controlling expression is constant
1890
1891         AC_CHECKING([for $CC warning options])
1892         cf_save_CFLAGS="$CFLAGS"
1893         EXTRA_CFLAGS="-Wall"
1894         for cf_opt in \
1895                 wd1419 \
1896                 wd1683 \
1897                 wd1684 \
1898                 wd193 \
1899                 wd593 \
1900                 wd279 \
1901                 wd810 \
1902                 wd869 \
1903                 wd981
1904         do
1905                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1906                 if AC_TRY_EVAL(ac_compile); then
1907                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1908                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1909                 fi
1910         done
1911         CFLAGS="$cf_save_CFLAGS"
1912
1913 elif test "$GCC" = yes
1914 then
1915         AC_CHECKING([for $CC warning options])
1916         cf_save_CFLAGS="$CFLAGS"
1917         EXTRA_CFLAGS=
1918         cf_warn_CONST=""
1919         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1920         for cf_opt in W Wall \
1921                 Wbad-function-cast \
1922                 Wcast-align \
1923                 Wcast-qual \
1924                 Winline \
1925                 Wmissing-declarations \
1926                 Wmissing-prototypes \
1927                 Wnested-externs \
1928                 Wpointer-arith \
1929                 Wshadow \
1930                 Wstrict-prototypes \
1931                 Wundef $cf_warn_CONST $1
1932         do
1933                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1934                 if AC_TRY_EVAL(ac_compile); then
1935                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1936                         case $cf_opt in #(vi
1937                         Wcast-qual) #(vi
1938                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1939                                 ;;
1940                         Winline) #(vi
1941                                 case $GCC_VERSION in
1942                                 [[34]].*)
1943                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1944                                         continue;;
1945                                 esac
1946                                 ;;
1947                         esac
1948                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1949                 fi
1950         done
1951         CFLAGS="$cf_save_CFLAGS"
1952 fi
1953 rm -rf conftest*
1954
1955 AC_SUBST(EXTRA_CFLAGS)
1956 ])dnl
1957 dnl ---------------------------------------------------------------------------
1958 dnl CF_GETOPT_HEADER version: 4 updated: 2009/08/31 20:07:52
1959 dnl ----------------
1960 dnl Check for getopt's variables which are commonly defined in stdlib.h,
1961 dnl unistd.h or (nonstandard) in getopt.h
1962 AC_DEFUN([CF_GETOPT_HEADER],
1963 [
1964 AC_HAVE_HEADERS(unistd.h getopt.h)
1965 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
1966 cf_cv_getopt_header=none
1967 for cf_header in stdio.h stdlib.h unistd.h getopt.h
1968 do
1969 AC_TRY_COMPILE([
1970 #include <$cf_header>],
1971 [int x = optind; char *y = optarg],
1972 [cf_cv_getopt_header=$cf_header
1973  break])
1974 done
1975 ])
1976 if test $cf_cv_getopt_header != none ; then
1977         AC_DEFINE(HAVE_GETOPT_HEADER)
1978 fi
1979 ])dnl
1980 dnl ---------------------------------------------------------------------------
1981 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
1982 dnl ----------------
1983 AC_DEFUN([CF_GNAT_GENERICS],
1984 [
1985 AC_REQUIRE([CF_GNAT_VERSION])
1986
1987 AC_MSG_CHECKING(if GNAT supports generics)
1988 case $cf_gnat_version in #(vi
1989 3.[[1-9]]*|[[4-9]].*) #(vi
1990         cf_gnat_generics=yes
1991         ;;
1992 *)
1993         cf_gnat_generics=no
1994         ;;
1995 esac
1996 AC_MSG_RESULT($cf_gnat_generics)
1997
1998 if test "$cf_gnat_generics" = yes
1999 then
2000         cf_compile_generics=generics
2001         cf_generic_objects="\${GENOBJS}"
2002 else
2003         cf_compile_generics=
2004         cf_generic_objects=
2005 fi
2006
2007 AC_SUBST(cf_compile_generics)
2008 AC_SUBST(cf_generic_objects)
2009 ])dnl
2010 dnl ---------------------------------------------------------------------------
2011 dnl CF_GNAT_PRAGMA_UNREF version: 1 updated: 2010/06/19 15:22:18
2012 dnl --------------------
2013 dnl Check if the gnat pragma "Unreferenced" works.
2014 AC_DEFUN([CF_GNAT_PRAGMA_UNREF],[
2015 AC_CACHE_CHECK(if GNAT pragma Unreferenced works,cf_cv_pragma_unreferenced,[
2016 CF_GNAT_TRY_LINK([procedure conftest;],
2017 [with Text_IO;
2018 with GNAT.OS_Lib;
2019 procedure conftest is
2020    test : Integer;
2021    pragma Unreferenced (test);
2022 begin
2023    test := 1;
2024    Text_IO.Put ("Hello World");
2025    Text_IO.New_Line;
2026    GNAT.OS_Lib.OS_Exit (0);
2027 end conftest;],
2028         [cf_cv_pragma_unreferenced=yes],
2029         [cf_cv_pragma_unreferenced=no])])
2030
2031 # if the pragma is supported, use it (needed in the Trace code).
2032 if test $cf_cv_pragma_unreferenced = yes ; then
2033         PRAGMA_UNREF=TRUE
2034 else
2035         PRAGMA_UNREF=FALSE
2036 fi
2037 AC_SUBST(PRAGMA_UNREF)
2038 ])dnl
2039 dnl ---------------------------------------------------------------------------
2040 dnl CF_GNAT_PROJECTS version: 2 updated: 2011/03/23 20:24:41
2041 dnl ----------------
2042 dnl GNAT projects are configured with ".gpr" project files.
2043 dnl GNAT libraries are a further development, using the project feature.
2044 AC_DEFUN([CF_GNAT_PROJECTS],
2045 [
2046 AC_REQUIRE([CF_GNAT_VERSION])
2047
2048 cf_gnat_libraries=no
2049 cf_gnat_projects=no
2050
2051 AC_MSG_CHECKING(if GNAT supports project files)
2052 case $cf_gnat_version in #(vi
2053 3.[[0-9]]*) #(vi
2054         ;;
2055 *)
2056         case $cf_cv_system_name in #(vi
2057         cygwin*) #(vi
2058                 ;;
2059         *)
2060                 mkdir conftest.src conftest.bin conftest.lib
2061                 cd conftest.src
2062                 rm -rf conftest* *~conftest*
2063                 cat >>library.gpr <<CF_EOF
2064 project Library is
2065   Kind := External ("LIB_KIND");
2066   for Library_Name use "ConfTest";
2067   for Object_Dir use ".";
2068   for Library_ALI_Dir use External("LIBRARY_DIR");
2069   for Library_Version use External ("SONAME");
2070   for Library_Kind use Kind;
2071   for Library_Dir use External("BUILD_DIR");
2072   Source_Dir := External ("SOURCE_DIR");
2073   for Source_Dirs use (Source_Dir);
2074   package Compiler is
2075      for Default_Switches ("Ada") use
2076        ("-g",
2077         "-O2",
2078         "-gnatafno",
2079         "-gnatVa",   -- All validity checks
2080         "-gnatwa");  -- Activate all optional errors
2081   end Compiler;
2082 end Library;
2083 CF_EOF
2084                 cat >>confpackage.ads <<CF_EOF
2085 package ConfPackage is
2086    procedure conftest;
2087 end ConfPackage;
2088 CF_EOF
2089                 cat >>confpackage.adb <<CF_EOF
2090 with Text_IO;
2091 package body ConfPackage is
2092    procedure conftest is
2093    begin
2094       Text_IO.Put ("Hello World");
2095       Text_IO.New_Line;
2096    end conftest;
2097 end ConfPackage;
2098 CF_EOF
2099                 if ( $cf_ada_make $ADAFLAGS \
2100                                 -Plibrary.gpr \
2101                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2102                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2103                                 -XSOURCE_DIR=`pwd` \
2104                                 -XSONAME=libConfTest.so.1 \
2105                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2106                         cf_gnat_projects=yes
2107                 fi
2108                 cd ..
2109                 if test -f conftest.lib/confpackage.ali
2110                 then
2111                         cf_gnat_libraries=yes
2112                 fi
2113                 rm -rf conftest* *~conftest*
2114                 ;;
2115         esac
2116         ;;
2117 esac
2118 AC_MSG_RESULT($cf_gnat_projects)
2119
2120 if test $cf_gnat_projects = yes
2121 then
2122         AC_MSG_CHECKING(if GNAT supports libraries)
2123         AC_MSG_RESULT($cf_gnat_libraries)
2124 fi
2125
2126 if test "$cf_gnat_projects" = yes
2127 then
2128         USE_OLD_MAKERULES="#"
2129         USE_GNAT_PROJECTS=""
2130 else
2131         USE_OLD_MAKERULES=""
2132         USE_GNAT_PROJECTS="#"
2133 fi
2134
2135 if test "$cf_gnat_libraries" = yes
2136 then
2137         USE_GNAT_LIBRARIES=""
2138 else
2139         USE_GNAT_LIBRARIES="#"
2140 fi
2141
2142 AC_SUBST(USE_OLD_MAKERULES)
2143 AC_SUBST(USE_GNAT_PROJECTS)
2144 AC_SUBST(USE_GNAT_LIBRARIES)
2145 ])dnl
2146 dnl ---------------------------------------------------------------------------
2147 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2148 dnl --------------
2149 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2150 dnl is noted that gnat may compile a tasking unit even for configurations which
2151 dnl fail at runtime.
2152 AC_DEFUN([CF_GNAT_SIGINT],[
2153 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2154 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2155
2156 package ConfTest is
2157
2158    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2159    pragma Unreserve_All_Interrupts;
2160    pragma Warnings (On);
2161
2162    protected Process is
2163       procedure Stop;
2164       function Continue return Boolean;
2165       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2166    private
2167       Done : Boolean := False;
2168    end Process;
2169
2170 end ConfTest;],
2171 [package body ConfTest is
2172    protected body Process is
2173       procedure Stop is
2174       begin
2175          Done := True;
2176       end Stop;
2177       function Continue return Boolean is
2178       begin
2179          return not Done;
2180       end Continue;
2181    end Process;
2182 end ConfTest;],
2183         [cf_cv_gnat_sigint=yes],
2184         [cf_cv_gnat_sigint=no])])
2185
2186 if test $cf_cv_gnat_sigint = yes ; then
2187         USE_GNAT_SIGINT=""
2188 else
2189         USE_GNAT_SIGINT="#"
2190 fi
2191 AC_SUBST(USE_GNAT_SIGINT)
2192 ])dnl
2193 dnl ---------------------------------------------------------------------------
2194 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2195 dnl ----------------
2196 dnl Verify that a test program compiles/links with GNAT.
2197 dnl $cf_ada_make is set to the program that compiles/links
2198 dnl $ADAFLAGS may be set to the GNAT flags.
2199 dnl
2200 dnl $1 is the text of the spec
2201 dnl $2 is the text of the body
2202 dnl $3 is the shell command to execute if successful
2203 dnl $4 is the shell command to execute if not successful
2204 AC_DEFUN([CF_GNAT_TRY_LINK],
2205 [
2206 rm -rf conftest* *~conftest*
2207 cat >>conftest.ads <<CF_EOF
2208 $1
2209 CF_EOF
2210 cat >>conftest.adb <<CF_EOF
2211 $2
2212 CF_EOF
2213 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2214 ifelse($3,,      :,[      $3])
2215 ifelse($4,,,[else
2216    $4])
2217 fi
2218 rm -rf conftest* *~conftest*
2219 ])dnl
2220 dnl ---------------------------------------------------------------------------
2221 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2222 dnl ---------------
2223 dnl Verify that a test program compiles and runs with GNAT
2224 dnl $cf_ada_make is set to the program that compiles/links
2225 dnl $ADAFLAGS may be set to the GNAT flags.
2226 dnl
2227 dnl $1 is the text of the spec
2228 dnl $2 is the text of the body
2229 dnl $3 is the shell command to execute if successful
2230 dnl $4 is the shell command to execute if not successful
2231 AC_DEFUN([CF_GNAT_TRY_RUN],
2232 [
2233 rm -rf conftest* *~conftest*
2234 cat >>conftest.ads <<CF_EOF
2235 $1
2236 CF_EOF
2237 cat >>conftest.adb <<CF_EOF
2238 $2
2239 CF_EOF
2240 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2241    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2242 ifelse($3,,      :,[      $3])
2243 ifelse($4,,,[   else
2244       $4])
2245    fi
2246 ifelse($4,,,[else
2247    $4])
2248 fi
2249 rm -rf conftest* *~conftest*
2250 ])dnl
2251 dnl ---------------------------------------------------------------------------
2252 dnl CF_GNAT_VERSION version: 18 updated: 2012/01/21 19:28:10
2253 dnl ---------------
2254 dnl Verify version of GNAT.
2255 AC_DEFUN([CF_GNAT_VERSION],
2256 [
2257 AC_MSG_CHECKING(for gnat version)
2258 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2259         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2260     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2261 AC_MSG_RESULT($cf_gnat_version)
2262
2263 case $cf_gnat_version in #(vi
2264 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]]) #(vi
2265         cf_cv_prog_gnat_correct=yes
2266         ;;
2267 *)
2268         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2269         cf_cv_prog_gnat_correct=no
2270         ;;
2271 esac
2272 ])
2273 dnl ---------------------------------------------------------------------------
2274 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2275 dnl -------------
2276 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2277 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2278 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2279 dnl since it is interwoven with GNU extensions.
2280 dnl
2281 dnl Well, yes we could work around it...
2282 AC_DEFUN([CF_GNU_SOURCE],
2283 [
2284 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2285 AC_TRY_COMPILE([#include <sys/types.h>],[
2286 #ifndef _XOPEN_SOURCE
2287 make an error
2288 #endif],
2289         [cf_cv_gnu_source=no],
2290         [cf_save="$CPPFLAGS"
2291          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2292          AC_TRY_COMPILE([#include <sys/types.h>],[
2293 #ifdef _XOPEN_SOURCE
2294 make an error
2295 #endif],
2296         [cf_cv_gnu_source=no],
2297         [cf_cv_gnu_source=yes])
2298         CPPFLAGS="$cf_save"
2299         ])
2300 ])
2301 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2302 ])dnl
2303 dnl ---------------------------------------------------------------------------
2304 dnl CF_GPP_LIBRARY version: 10 updated: 2010/05/29 16:31:02
2305 dnl --------------
2306 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2307 dnl problem :-).  If we have the compiler but no library, we'll be able to
2308 dnl configure, but won't be able to build the c++ demo program.
2309 AC_DEFUN([CF_GPP_LIBRARY],
2310 [
2311 cf_cxx_library=unknown
2312 case $cf_cv_system_name in #(vi
2313 os2*) #(vi
2314         cf_gpp_libname=gpp
2315         ;;
2316 *)
2317         cf_gpp_libname=g++
2318         ;;
2319 esac
2320 if test "$GXX" = yes; then
2321         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2322         cf_save="$LIBS"
2323         CF_ADD_LIB($cf_gpp_libname)
2324         AC_TRY_LINK([
2325 #include <$cf_gpp_libname/builtin.h>
2326         ],
2327         [two_arg_error_handler_t foo2 = lib_error_handler],
2328         [cf_cxx_library=yes
2329          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2330          if test "$cf_gpp_libname" = cpp ; then
2331             AC_DEFINE(HAVE_GPP_BUILTIN_H)
2332          else
2333             AC_DEFINE(HAVE_GXX_BUILTIN_H)
2334          fi],
2335         [AC_TRY_LINK([
2336 #include <builtin.h>
2337         ],
2338         [two_arg_error_handler_t foo2 = lib_error_handler],
2339         [cf_cxx_library=yes
2340          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2341          AC_DEFINE(HAVE_BUILTIN_H)],
2342         [cf_cxx_library=no])])
2343         LIBS="$cf_save"
2344         AC_MSG_RESULT($cf_cxx_library)
2345 fi
2346 ])dnl
2347 dnl ---------------------------------------------------------------------------
2348 dnl CF_GXX_VERSION version: 6 updated: 2010/10/23 15:44:18
2349 dnl --------------
2350 dnl Check for version of g++
2351 AC_DEFUN([CF_GXX_VERSION],[
2352 AC_REQUIRE([AC_PROG_CPP])
2353 GXX_VERSION=none
2354 if test "$GXX" = yes; then
2355         AC_MSG_CHECKING(version of g++)
2356         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2357         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2358         AC_MSG_RESULT($GXX_VERSION)
2359 fi
2360 ])dnl
2361 dnl ---------------------------------------------------------------------------
2362 dnl CF_GXX_WARNINGS version: 6 updated: 2010/08/14 18:25:37
2363 dnl ---------------
2364 dnl Check if the compiler supports useful warning options.
2365 dnl
2366 dnl Most of gcc's options apply to g++, except:
2367 dnl     -Wbad-function-cast
2368 dnl     -Wmissing-declarations
2369 dnl     -Wnested-externs
2370 dnl
2371 dnl Omit a few (for now):
2372 dnl     -Winline
2373 dnl
2374 dnl Parameter:
2375 dnl     $1 is an optional list of g++ warning flags that a particular
2376 dnl             application might want to use, e.g., "no-unused" for
2377 dnl             -Wno-unused
2378 dnl Special:
2379 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2380 dnl
2381 AC_DEFUN([CF_GXX_WARNINGS],
2382 [
2383
2384 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2385
2386 AC_REQUIRE([CF_GXX_VERSION])
2387
2388 AC_LANG_SAVE
2389 AC_LANG_CPLUSPLUS
2390
2391 cat > conftest.$ac_ext <<EOF
2392 #line __oline__ "configure"
2393 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2394 EOF
2395
2396 if test "$INTEL_CPLUSPLUS" = yes
2397 then
2398 # The "-wdXXX" options suppress warnings:
2399 # remark #1419: external declaration in primary source file
2400 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2401 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2402 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2403 # remark #193: zero used for undefined preprocessing identifier
2404 # remark #593: variable "curs_sb_left_arrow" was set but never used
2405 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2406 # remark #869: parameter "tw" was never referenced
2407 # remark #981: operands are evaluated in unspecified order
2408 # warning #269: invalid format string conversion
2409
2410         AC_CHECKING([for $CC warning options])
2411         cf_save_CXXFLAGS="$CXXFLAGS"
2412         EXTRA_CXXFLAGS="-Wall"
2413         for cf_opt in \
2414                 wd1419 \
2415                 wd1682 \
2416                 wd1683 \
2417                 wd1684 \
2418                 wd193 \
2419                 wd279 \
2420                 wd593 \
2421                 wd810 \
2422                 wd869 \
2423                 wd981
2424         do
2425                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2426                 if AC_TRY_EVAL(ac_compile); then
2427                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2428                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2429                 fi
2430         done
2431         CXXFLAGS="$cf_save_CXXFLAGS"
2432
2433 elif test "$GXX" = yes
2434 then
2435         AC_CHECKING([for $CXX warning options])
2436         cf_save_CXXFLAGS="$CXXFLAGS"
2437         EXTRA_CXXFLAGS="-W -Wall"
2438         cf_gxx_extra_warnings=""
2439         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2440         case "$GCC_VERSION" in
2441         [[1-2]].*)
2442                 ;;
2443         *)
2444                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2445                 ;;
2446         esac
2447         for cf_opt in \
2448                 Wabi \
2449                 fabi-version=0 \
2450                 Woverloaded-virtual \
2451                 Wsign-promo \
2452                 Wsynth \
2453                 Wold-style-cast \
2454                 Wcast-align \
2455                 Wcast-qual \
2456                 Wmissing-prototypes \
2457                 Wpointer-arith \
2458                 Wshadow \
2459                 Wstrict-prototypes \
2460                 Wundef $cf_gxx_extra_warnings $1
2461         do
2462                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2463                 if AC_TRY_EVAL(ac_compile); then
2464                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2465                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2466                 else
2467                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2468                 fi
2469         done
2470         CXXFLAGS="$cf_save_CXXFLAGS"
2471 fi
2472
2473 rm -rf conftest*
2474 AC_LANG_RESTORE
2475 AC_SUBST(EXTRA_CXXFLAGS)
2476 ])dnl
2477 dnl ---------------------------------------------------------------------------
2478 dnl CF_HASHED_DB version: 4 updated: 2010/05/29 16:31:02
2479 dnl ------------
2480 dnl Look for an instance of the Berkeley hashed database.
2481 dnl
2482 dnl $1 = optional parameter, to specify install-prefix for the database.
2483 AC_DEFUN([CF_HASHED_DB],
2484 [
2485 ifelse([$1],,,[
2486 case $1 in #(vi
2487 yes|*able*) #(vi
2488     ;;
2489 *)
2490     if test -d "$1" ; then
2491         CF_ADD_INCDIR($1/include)
2492         CF_ADD_LIBDIR($1/lib)
2493     fi
2494 esac
2495 ])
2496 AC_CHECK_HEADER(db.h,[
2497 CF_HASHED_DB_VERSION
2498 if test "$cf_cv_hashed_db_version" = unknown ; then
2499         AC_MSG_ERROR(Cannot determine version of db)
2500 else
2501         CF_HASHED_DB_LIBS
2502         if test "$cf_cv_hashed_db_libs" = unknown ; then
2503                 AC_MSG_ERROR(Cannot determine library for db)
2504         elif test "$cf_cv_hashed_db_libs" != default ; then
2505                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2506         fi
2507 fi
2508 ],[
2509         AC_MSG_ERROR(Cannot find db.h)
2510 ])
2511 ])dnl
2512 dnl ---------------------------------------------------------------------------
2513 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2514 dnl -----------------
2515 dnl Given that we have the header and version for hashed database, find the
2516 dnl library information.
2517 AC_DEFUN([CF_HASHED_DB_LIBS],
2518 [
2519 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2520 cf_cv_hashed_db_libs=unknown
2521 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2522 do
2523         cf_save_libs="$LIBS"
2524         if test -n "$cf_db_libs"; then
2525                 CF_ADD_LIB($cf_db_libs)
2526         fi
2527         CF_MSG_LOG(checking for library "$cf_db_libs")
2528         AC_TRY_LINK([
2529 $ac_includes_default
2530 #include <db.h>
2531 ],[
2532         char *path = "/tmp/foo";
2533 #ifdef DB_VERSION_MAJOR
2534 #if DB_VERSION_MAJOR >= 4
2535         DB *result = 0;
2536         db_create(&result, NULL, 0);
2537         result->open(result,
2538                 NULL,
2539                 path,
2540                 path,
2541                 DB_HASH,
2542                 DB_CREATE,
2543                 0644);
2544 #elif DB_VERSION_MAJOR >= 3
2545         DB *result = 0;
2546         db_create(&result, NULL, 0);
2547         result->open(result,
2548                 path,
2549                 path,
2550                 DB_HASH,
2551                 DB_CREATE,
2552                 0644);
2553 #elif DB_VERSION_MAJOR >= 2
2554         DB *result = 0;
2555         db_open(path,
2556                 DB_HASH,
2557                 DB_CREATE,
2558                 0644,
2559                 (DB_ENV *) 0,
2560                 (DB_INFO *) 0,
2561                 &result);
2562 #endif /* DB_VERSION_MAJOR */
2563 #else
2564         DB *result = dbopen(path,
2565                      2,
2566                      0644,
2567                      DB_HASH,
2568                      0);
2569 #endif
2570         ${cf_cv_main_return:-return}(result != 0)
2571 ],[
2572         if test -n "$cf_db_libs" ; then
2573                 cf_cv_hashed_db_libs=$cf_db_libs
2574         else
2575                 cf_cv_hashed_db_libs=default
2576         fi
2577         LIBS="$cf_save_libs"
2578         break
2579 ])
2580         LIBS="$cf_save_libs"
2581 done
2582 ])
2583 ])dnl
2584 dnl ---------------------------------------------------------------------------
2585 dnl CF_HASHED_DB_VERSION version: 3 updated: 2007/12/01 15:01:37
2586 dnl --------------------
2587 dnl Given that we have the header file for hashed database, find the version
2588 dnl information.
2589 AC_DEFUN([CF_HASHED_DB_VERSION],
2590 [
2591 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2592 cf_cv_hashed_db_version=unknown
2593
2594 for cf_db_version in 1 2 3 4 5
2595 do
2596         CF_MSG_LOG(checking for db version $cf_db_version)
2597         AC_TRY_COMPILE([
2598 $ac_includes_default
2599 #include <db.h>
2600
2601 #ifdef DB_VERSION_MAJOR
2602         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2603 #if $cf_db_version == DB_VERSION_MAJOR
2604         /* ok */
2605 #else
2606         make an error
2607 #endif
2608 #else
2609 #if $cf_db_version == 1
2610         /* ok: assuming this is DB 1.8.5 */
2611 #else
2612         make an error
2613 #endif
2614 #endif
2615 ],[DBT *foo = 0],[
2616         cf_cv_hashed_db_version=$cf_db_version
2617         break
2618         ])
2619 done
2620 ])
2621 ])dnl
2622 dnl ---------------------------------------------------------------------------
2623 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
2624 dnl --------------
2625 dnl Construct a search-list of directories for a nonstandard header-file
2626 dnl
2627 dnl Parameters
2628 dnl     $1 = the variable to return as result
2629 dnl     $2 = the package name
2630 AC_DEFUN([CF_HEADER_PATH],
2631 [
2632 $1=
2633
2634 # collect the current set of include-directories from compiler flags
2635 cf_header_path_list=""
2636 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2637         for cf_header_path in $CPPFLAGS $CFLAGS
2638         do
2639                 case $cf_header_path in #(vi
2640                 -I*)
2641                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2642                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2643                         cf_header_path_list="$cf_header_path_list [$]$1"
2644                         ;;
2645                 esac
2646         done
2647 fi
2648
2649 # add the variations for the package we are looking for
2650 CF_SUBDIR_PATH($1,$2,include)
2651
2652 test "$includedir" != NONE && \
2653 test "$includedir" != "/usr/include" && \
2654 test -d "$includedir" && {
2655         test -d $includedir &&    $1="[$]$1 $includedir"
2656         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2657 }
2658
2659 test "$oldincludedir" != NONE && \
2660 test "$oldincludedir" != "/usr/include" && \
2661 test -d "$oldincludedir" && {
2662         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2663         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2664 }
2665
2666 $1="[$]$1 $cf_header_path_list"
2667 ])dnl
2668 dnl ---------------------------------------------------------------------------
2669 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2670 dnl ---------------
2671 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2672 AC_DEFUN([CF_HELP_MESSAGE],
2673 [AC_DIVERT_HELP([$1])dnl
2674 ])dnl
2675 dnl ---------------------------------------------------------------------------
2676 dnl CF_INCLUDE_DIRS version: 6 updated: 2009/01/06 19:37:40
2677 dnl ---------------
2678 dnl Construct the list of include-options according to whether we're building
2679 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
2680 dnl with gcc, don't append the includedir if it happens to be /usr/include,
2681 dnl since that usually breaks gcc's shadow-includes.
2682 AC_DEFUN([CF_INCLUDE_DIRS],
2683 [
2684 CPPFLAGS="$CPPFLAGS -I. -I../include"
2685 if test "$srcdir" != "."; then
2686         CPPFLAGS="$CPPFLAGS -I\${srcdir}/../include"
2687 fi
2688 if test "$GCC" != yes; then
2689         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2690 elif test "$includedir" != "/usr/include"; then
2691         if test "$includedir" = '${prefix}/include' ; then
2692                 if test $prefix != /usr ; then
2693                         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2694                 fi
2695         else
2696                 CPPFLAGS="$CPPFLAGS -I\${includedir}"
2697         fi
2698 fi
2699 AC_SUBST(CPPFLAGS)
2700 ])dnl
2701 dnl ---------------------------------------------------------------------------
2702 dnl CF_INTEL_COMPILER version: 4 updated: 2010/05/26 05:38:42
2703 dnl -----------------
2704 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2705 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2706 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2707 dnl
2708 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2709 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2710 dnl the wrappers for gcc and g++ warnings.
2711 dnl
2712 dnl $1 = GCC (default) or GXX
2713 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2714 dnl $3 = CFLAGS (default) or CXXFLAGS
2715 AC_DEFUN([CF_INTEL_COMPILER],[
2716 ifelse([$2],,INTEL_COMPILER,[$2])=no
2717
2718 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2719         case $host_os in
2720         linux*|gnu*)
2721                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2722                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2723                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2724                 AC_TRY_COMPILE([],[
2725 #ifdef __INTEL_COMPILER
2726 #else
2727 make an error
2728 #endif
2729 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2730 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
2731 ],[])
2732                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2733                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2734                 ;;
2735         esac
2736 fi
2737 ])dnl
2738 dnl ---------------------------------------------------------------------------
2739 dnl CF_ISASCII version: 3 updated: 2000/08/12 23:18:52
2740 dnl ----------
2741 dnl Check if we have either a function or macro for 'isascii()'.
2742 AC_DEFUN([CF_ISASCII],
2743 [
2744 AC_MSG_CHECKING(for isascii)
2745 AC_CACHE_VAL(cf_cv_have_isascii,[
2746         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2747         [cf_cv_have_isascii=yes],
2748         [cf_cv_have_isascii=no])
2749 ])dnl
2750 AC_MSG_RESULT($cf_cv_have_isascii)
2751 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII)
2752 ])dnl
2753 dnl ---------------------------------------------------------------------------
2754 dnl CF_LARGEFILE version: 7 updated: 2007/06/02 11:58:50
2755 dnl ------------
2756 dnl Add checks for large file support.
2757 AC_DEFUN([CF_LARGEFILE],[
2758 ifdef([AC_FUNC_FSEEKO],[
2759     AC_SYS_LARGEFILE
2760     if test "$enable_largefile" != no ; then
2761         AC_FUNC_FSEEKO
2762
2763         # Normally we would collect these definitions in the config.h,
2764         # but (like _XOPEN_SOURCE), some environments rely on having these
2765         # defined before any of the system headers are included.  Another
2766         # case comes up with C++, e.g., on AIX the compiler compiles the
2767         # header files by themselves before looking at the body files it is
2768         # told to compile.  For ncurses, those header files do not include
2769         # the config.h
2770         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2771         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2772         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2773
2774         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2775                 AC_TRY_COMPILE([
2776 #include <sys/types.h>
2777 #include <dirent.h>
2778                 ],[
2779                 /* if transitional largefile support is setup, this is true */
2780                 extern struct dirent64 * readdir(DIR *);
2781                 struct dirent64 *x = readdir((DIR *)0);
2782                 struct dirent *y = readdir((DIR *)0);
2783                 int z = x - y;
2784                 ],
2785                 [cf_cv_struct_dirent64=yes],
2786                 [cf_cv_struct_dirent64=no])
2787         ])
2788         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64)
2789     fi
2790 ])
2791 ])
2792 dnl ---------------------------------------------------------------------------
2793 dnl CF_LDFLAGS_STATIC version: 10 updated: 2011/09/24 12:51:48
2794 dnl -----------------
2795 dnl Check for compiler/linker flags used to temporarily force usage of static
2796 dnl libraries.  This depends on the compiler and platform.  Use this to help
2797 dnl ensure that the linker picks up a given library based on its position in
2798 dnl the list of linker options and libraries.
2799 AC_DEFUN([CF_LDFLAGS_STATIC],[
2800
2801 if test "$GCC" = yes ; then
2802         case $cf_cv_system_name in #(
2803         OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)         #( vi
2804                 LDFLAGS_STATIC=
2805                 LDFLAGS_SHARED=
2806                 ;;
2807     *)  #( normally, except when broken
2808         LDFLAGS_STATIC=-static
2809         LDFLAGS_SHARED=-dynamic
2810         ;;
2811     esac
2812 else
2813         case $cf_cv_system_name in #(
2814         aix[[4-7]]*)    #( from ld manpage
2815                 LDFLAGS_STATIC=-bstatic
2816                 LDFLAGS_SHARED=-bdynamic
2817                 ;;
2818         hpux*)          #( from ld manpage for hpux10.20, hpux11.11
2819                 # We could also use just "archive" and "shared".
2820                 LDFLAGS_STATIC=-Wl,-a,archive_shared
2821                 LDFLAGS_SHARED=-Wl,-a,shared_archive
2822                 ;;
2823         irix*)          #( from ld manpage IRIX64
2824                 LDFLAGS_STATIC=-Bstatic
2825                 LDFLAGS_SHARED=-Bdynamic
2826                 ;;
2827         osf[[45]]*)     #( from ld manpage osf4.0d, osf5.1
2828                 # alternative "-oldstyle_liblookup" (not in cc manpage)
2829                 LDFLAGS_STATIC=-noso
2830                 LDFLAGS_SHARED=-so_archive
2831                 ;;
2832         solaris2*)
2833                 LDFLAGS_STATIC=-Bstatic
2834                 LDFLAGS_SHARED=-Bdynamic
2835                 ;;
2836         esac
2837 fi
2838
2839 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
2840 then
2841         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
2842
2843         rm -f libconftest.a
2844         cat >conftest.$ac_ext <<EOF
2845 #line __oline__ "configure"
2846 #include <stdio.h>
2847 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
2848 EOF
2849         if AC_TRY_EVAL(ac_compile) ; then
2850                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
2851                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
2852         fi
2853         rm -f conftest.*
2854
2855         cf_save_LIBS="$LIBS"
2856
2857         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
2858         AC_TRY_LINK([
2859 #line __oline__ "configure"
2860 #include <stdio.h>
2861 int cf_ldflags_static(FILE *fp);
2862 ],[
2863         return cf_ldflags_static(stdin);
2864 ],[
2865         # some linkers simply ignore the -dynamic
2866         case x`file conftest$ac_exeext 2>/dev/null` in #(vi
2867         *static*) # (vi
2868                 cf_ldflags_static=no
2869                 ;;
2870         *)
2871                 cf_ldflags_static=yes
2872                 ;;
2873         esac
2874 ],[cf_ldflags_static=no])
2875
2876         rm -f libconftest.*
2877         LIBS="$cf_save_LIBS"
2878
2879         AC_MSG_RESULT($cf_ldflags_static)
2880
2881         if test $cf_ldflags_static != yes
2882         then
2883                 LDFLAGS_STATIC=
2884                 LDFLAGS_SHARED=
2885         fi
2886 else
2887         LDFLAGS_STATIC=
2888         LDFLAGS_SHARED=
2889 fi
2890
2891 AC_SUBST(LDFLAGS_STATIC)
2892 AC_SUBST(LDFLAGS_SHARED)
2893 ])
2894 dnl ---------------------------------------------------------------------------
2895 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
2896 dnl ---------------
2897 dnl For the given system and compiler, find the compiler flags to pass to the
2898 dnl loader to use the "rpath" feature.
2899 AC_DEFUN([CF_LD_RPATH_OPT],
2900 [
2901 AC_REQUIRE([CF_CHECK_CACHE])
2902
2903 LD_RPATH_OPT=
2904 AC_MSG_CHECKING(for an rpath option)
2905 case $cf_cv_system_name in #(vi
2906 irix*) #(vi
2907         if test "$GCC" = yes; then
2908                 LD_RPATH_OPT="-Wl,-rpath,"
2909         else
2910                 LD_RPATH_OPT="-rpath "
2911         fi
2912         ;;
2913 linux*|gnu*|k*bsd*-gnu) #(vi
2914         LD_RPATH_OPT="-Wl,-rpath,"
2915         ;;
2916 openbsd[[2-9]].*|mirbsd*) #(vi
2917         LD_RPATH_OPT="-Wl,-rpath,"
2918         ;;
2919 dragonfly*|freebsd*) #(vi
2920         LD_RPATH_OPT="-rpath "
2921         ;;
2922 netbsd*) #(vi
2923         LD_RPATH_OPT="-Wl,-rpath,"
2924         ;;
2925 osf*|mls+*) #(vi
2926         LD_RPATH_OPT="-rpath "
2927         ;;
2928 solaris2*) #(vi
2929         LD_RPATH_OPT="-R"
2930         ;;
2931 *)
2932         ;;
2933 esac
2934 AC_MSG_RESULT($LD_RPATH_OPT)
2935
2936 case "x$LD_RPATH_OPT" in #(vi
2937 x-R*)
2938         AC_MSG_CHECKING(if we need a space after rpath option)
2939         cf_save_LIBS="$LIBS"
2940         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
2941         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
2942         LIBS="$cf_save_LIBS"
2943         AC_MSG_RESULT($cf_rpath_space)
2944         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
2945         ;;
2946 esac
2947 ])dnl
2948 dnl ---------------------------------------------------------------------------
2949 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
2950 dnl ---------------
2951 dnl Construct a search-list of directories for a nonstandard library-file
2952 dnl
2953 dnl Parameters
2954 dnl     $1 = the variable to return as result
2955 dnl     $2 = the package name
2956 AC_DEFUN([CF_LIBRARY_PATH],
2957 [
2958 $1=
2959 cf_library_path_list=""
2960 if test -n "${LDFLAGS}${LIBS}" ; then
2961         for cf_library_path in $LDFLAGS $LIBS
2962         do
2963                 case $cf_library_path in #(vi
2964                 -L*)
2965                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
2966                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
2967                         cf_library_path_list="$cf_library_path_list [$]$1"
2968                         ;;
2969                 esac
2970         done
2971 fi
2972
2973 CF_SUBDIR_PATH($1,$2,lib)
2974
2975 $1="$cf_library_path_list [$]$1"
2976 ])dnl
2977 dnl ---------------------------------------------------------------------------
2978 dnl CF_LIB_PREFIX version: 9 updated: 2012/01/21 19:28:10
2979 dnl -------------
2980 dnl Compute the library-prefix for the given host system
2981 dnl $1 = variable to set
2982 define([CF_LIB_PREFIX],
2983 [
2984         case $cf_cv_system_name in #(vi
2985         OS/2*|os2*) #(vi
2986         LIB_PREFIX=''
2987         ;;
2988         *)      LIB_PREFIX='lib'
2989         ;;
2990         esac
2991 ifelse($1,,,[$1=$LIB_PREFIX])
2992         AC_SUBST(LIB_PREFIX)
2993 ])dnl
2994 dnl ---------------------------------------------------------------------------
2995 dnl CF_LIB_RULES version: 63 updated: 2012/01/21 19:28:10
2996 dnl ------------
2997 dnl Append definitions and rules for the given models to the subdirectory
2998 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
2999 dnl subdirectory is a library-source directory, modify the LIBS_TO_MAKE list in
3000 dnl the corresponding makefile to list the models that we'll generate.
3001 dnl
3002 dnl For shared libraries, make a list of symbolic links to construct when
3003 dnl generating each library.  The convention used for Linux is the simplest
3004 dnl one:
3005 dnl     lib<name>.so    ->
3006 dnl     lib<name>.so.<major>    ->
3007 dnl     lib<name>.so.<maj>.<minor>
3008 AC_DEFUN([CF_LIB_RULES],
3009 [
3010 cf_prefix=$LIB_PREFIX
3011 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3012
3013 if test $cf_cv_shlib_version = cygdll ; then
3014         TINFO_NAME=$TINFO_ARG_SUFFIX
3015         TINFO_SUFFIX=.dll
3016 fi
3017
3018 if test -n "$TINFO_SUFFIX" ; then
3019         case $TINFO_SUFFIX in
3020         tw*)
3021                 TINFO_NAME="${TINFO_NAME}tw"
3022                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw//'`
3023                 ;;
3024         t*)
3025                 TINFO_NAME="${TINFO_NAME}t"
3026                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t//'`
3027                 ;;
3028         w*)
3029                 TINFO_NAME="${TINFO_NAME}w"
3030                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w//'`
3031                 ;;
3032         esac
3033 fi
3034
3035 for cf_dir in $SRC_SUBDIRS
3036 do
3037         if test ! -d $srcdir/$cf_dir ; then
3038                 continue
3039         elif test -f $srcdir/$cf_dir/modules; then
3040
3041                 SHARED_LIB=
3042                 LIBS_TO_MAKE=
3043                 for cf_item in $cf_LIST_MODELS
3044                 do
3045                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3046                         if test $cf_item = shared ; then
3047                         if test "$cf_cv_do_symlinks" = yes ; then
3048                                 case "$cf_cv_shlib_version" in #(vi
3049                                 rel) #(vi
3050                                         case "$cf_cv_system_name" in #(vi
3051                                         darwin*)
3052                                         case .${LIB_SUFFIX} in
3053                                         .tw*)
3054                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3055                                                 cf_suffix=tw'.${REL_VERSION}'"$cf_suffix"
3056                                                 ;;
3057                                         .t*)
3058                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3059                                                 cf_suffix=t'.${REL_VERSION}'"$cf_suffix"
3060                                                 ;;
3061                                         .w*)
3062                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3063                                                 cf_suffix=w'.${REL_VERSION}'"$cf_suffix"
3064                                                 ;;
3065                                         *)
3066                                                 cf_suffix='.${REL_VERSION}'"$cf_suffix"
3067                                                 ;;
3068                                         esac
3069                                         ;; #(vi
3070                                         *) cf_suffix="$cf_suffix"'.${REL_VERSION}' ;;
3071                                         esac
3072                                         ;;
3073                                 abi)
3074                                         case "$cf_cv_system_name" in #(vi
3075                                         darwin*)
3076                                         case .${LIB_SUFFIX} in
3077                                         .tw*)
3078                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3079                                                 cf_suffix=tw'.${ABI_VERSION}'"$cf_suffix"
3080                                                 ;;
3081                                         .t*)
3082                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3083                                                 cf_suffix=t'.${ABI_VERSION}'"$cf_suffix"
3084                                                 ;;
3085                                         .w*)
3086                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3087                                                 cf_suffix=w'.${ABI_VERSION}'"$cf_suffix"
3088                                                 ;;
3089                                         *)
3090                                                 cf_suffix='.${ABI_VERSION}'"$cf_suffix"
3091                                                 ;;
3092                                         esac
3093                                         ;; #(vi
3094                                         *) cf_suffix="$cf_suffix"'.${ABI_VERSION}' ;;
3095                                         esac
3096                                         ;;
3097                                 esac
3098                         fi
3099                         # cygwin needs import library, and has unique naming convention
3100                         # use autodetected ${cf_prefix} for import lib and static lib, but
3101                         # use 'cyg' prefix for shared lib.
3102                         if test $cf_cv_shlib_version = cygdll ; then
3103                                 cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3104                                 LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/cyg${cf_dir}${cf_cygsuf}"
3105                                 continue
3106                         fi
3107                         fi
3108                         LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/${cf_prefix}${cf_dir}${cf_suffix}"
3109                 done
3110
3111                 if test $cf_dir = ncurses ; then
3112                         cf_subsets="$LIB_SUBSETS"
3113                         cf_r_parts="$cf_subsets"
3114                         cf_liblist="$LIBS_TO_MAKE"
3115
3116                         while test -n "$cf_r_parts"
3117                         do
3118                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3119                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3120                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3121                                         cf_item=
3122                                         case $cf_l_parts in #(vi
3123                                         *termlib*) #(vi
3124                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3125                                                 ;;
3126                                         *ticlib*)
3127                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3128                                                 ;;
3129                                         *)
3130                                                 break
3131                                                 ;;
3132                                         esac
3133                                         if test -n "$cf_item"; then
3134                                                 LIBS_TO_MAKE="$cf_item $LIBS_TO_MAKE"
3135                                         fi
3136                                 else
3137                                         break
3138                                 fi
3139                         done
3140                 else
3141                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3142                 fi
3143
3144                 sed -e "s%@LIBS_TO_MAKE@%$LIBS_TO_MAKE%" \
3145                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3146                         $cf_dir/Makefile >$cf_dir/Makefile.out
3147                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3148
3149                 $AWK -f $srcdir/mk-0th.awk \
3150                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" \
3151                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3152
3153                 for cf_subset in $cf_subsets
3154                 do
3155                         cf_subdirs=
3156                         for cf_item in $cf_LIST_MODELS
3157                         do
3158                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3159                         CF_UPPER(cf_ITEM,$cf_item)
3160                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3161                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3162
3163                         # Test for case where we build libtinfo with a different name.
3164                         cf_libname=$cf_dir
3165                         if test $cf_dir = ncurses ; then
3166                                 case $cf_subset in
3167                                 *base*)
3168                                         cf_libname=${cf_libname}$LIB_SUFFIX
3169                                         ;;
3170                                 *termlib*)
3171                                         cf_libname=$TINFO_LIB_SUFFIX
3172                                         ;;
3173                                 ticlib*)
3174                                         cf_libname=$TICS_LIB_SUFFIX
3175                                         ;;
3176                                 esac
3177                         else
3178                                 cf_libname=${cf_libname}$LIB_SUFFIX
3179                         fi
3180                         if test -n "${DFT_ARG_SUFFIX}" ; then
3181                                 # undo $LIB_SUFFIX add-on in CF_LIB_SUFFIX
3182                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${LIB_SUFFIX}%%"`
3183                         fi
3184
3185                         # These dependencies really are for development, not
3186                         # builds, but they are useful in porting, too.
3187                         cf_depend="../include/ncurses_cfg.h"
3188                         if test "$srcdir" = "."; then
3189                                 cf_reldir="."
3190                         else
3191                                 cf_reldir="\${srcdir}"
3192                         fi
3193
3194                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3195                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3196                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3197                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3198                         fi
3199
3200                         cf_dir_suffix=
3201                         old_cf_suffix="$cf_suffix"
3202                         if test "$cf_cv_shlib_version_infix" = yes ; then
3203                         if test -n "$LIB_SUFFIX" ; then
3204                                 case $LIB_SUFFIX in
3205                                 tw*)
3206                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
3207                                         cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3208                                         cf_dir_suffix=tw
3209                                         ;;
3210                                 t*)
3211                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
3212                                         cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3213                                         cf_dir_suffix=t
3214                                         ;;
3215                                 w*)
3216                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
3217                                         cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3218                                         cf_dir_suffix=w
3219                                         ;;
3220                                 esac
3221                         fi
3222                         fi
3223
3224                         $AWK -f $srcdir/mk-1st.awk \
3225                                 name=${cf_libname}${cf_dir_suffix} \
3226                                 traces=$LIB_TRACING \
3227                                 MODEL=$cf_ITEM \
3228                                 model=$cf_subdir \
3229                                 prefix=$cf_prefix \
3230                                 suffix=$cf_suffix \
3231                                 subset=$cf_subset \
3232                                 driver=$cf_cv_term_driver \
3233                                 SymLink="$LN_S" \
3234                                 TermlibRoot=$TINFO_NAME \
3235                                 TermlibSuffix=$TINFO_SUFFIX \
3236                                 ShlibVer=$cf_cv_shlib_version \
3237                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3238                                 ReLink=${cf_cv_do_relink:-no} \
3239                                 DoLinks=$cf_cv_do_symlinks \
3240                                 rmSoLocs=$cf_cv_rm_so_locs \
3241                                 ldconfig="$LDCONFIG" \
3242                                 overwrite=$WITH_OVERWRITE \
3243                                 depend="$cf_depend" \
3244                                 host="$host" \
3245                                 libtool_version="$LIBTOOL_VERSION" \
3246                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3247
3248                         cf_suffix="$old_cf_suffix"
3249
3250                         for cf_subdir2 in $cf_subdirs lib
3251                         do
3252                                 test $cf_subdir = $cf_subdir2 && break
3253                         done
3254                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3255                         $AWK -f $srcdir/mk-2nd.awk \
3256                                 name=$cf_dir \
3257                                 traces=$LIB_TRACING \
3258                                 MODEL=$cf_ITEM \
3259                                 model=$cf_subdir \
3260                                 subset=$cf_subset \
3261                                 srcdir=$srcdir \
3262                                 echo=$WITH_ECHO \
3263                                 crenames=$cf_cv_prog_CC_c_o \
3264                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3265                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3266                         cf_subdirs="$cf_subdirs $cf_subdir"
3267                         done
3268                 done
3269         fi
3270
3271         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >>Makefile
3272 done
3273
3274 for cf_dir in $SRC_SUBDIRS
3275 do
3276         if test ! -d $srcdir/$cf_dir ; then
3277                 continue
3278         fi
3279
3280         if test -f $cf_dir/Makefile ; then
3281                 case "$cf_dir" in
3282                 Ada95) #(vi
3283                         echo 'libs \' >> Makefile
3284                         echo 'install.libs \' >> Makefile
3285                         echo 'uninstall.libs ::' >> Makefile
3286                         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >> Makefile
3287                         ;;
3288                 esac
3289         fi
3290
3291         if test -f $srcdir/$cf_dir/modules; then
3292                 echo >> Makefile
3293                 if test -f $srcdir/$cf_dir/headers; then
3294 cat >> Makefile <<CF_EOF
3295 install.includes \\
3296 uninstall.includes \\
3297 CF_EOF
3298                 fi
3299 if test "$cf_dir" != "c++" ; then
3300 echo 'lint \' >> Makefile
3301 fi
3302 cat >> Makefile <<CF_EOF
3303 libs \\
3304 lintlib \\
3305 install.libs \\
3306 uninstall.libs \\
3307 install.$cf_dir \\
3308 uninstall.$cf_dir ::
3309         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
3310 CF_EOF
3311         elif test -f $srcdir/$cf_dir/headers; then
3312 cat >> Makefile <<CF_EOF
3313
3314 libs \\
3315 install.libs \\
3316 uninstall.libs \\
3317 install.includes \\
3318 uninstall.includes ::
3319         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
3320 CF_EOF
3321 fi
3322 done
3323
3324 cat >> Makefile <<CF_EOF
3325
3326 install.libs uninstall.libs \\
3327 install.data uninstall.data ::
3328 $MAKE_TERMINFO  cd misc && \${MAKE} \${CF_MFLAGS} \[$]@
3329 CF_EOF
3330
3331 if test "x$cf_with_manpages" = xyes; then
3332 cat >> Makefile <<CF_EOF
3333
3334 install.man \\
3335 uninstall.man ::
3336         cd man && \${MAKE} \${CF_MFLAGS} \[$]@
3337 CF_EOF
3338 fi
3339
3340 cat >> Makefile <<CF_EOF
3341
3342 distclean ::
3343         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3344         rm -f headers.sh headers.sed mk_shared_lib.sh
3345         rm -f edit_man.* man_alias.*
3346         rm -rf \${DIRS_TO_MAKE}
3347 CF_EOF
3348
3349 # Special case: tack's manpage lives in its own directory.
3350 if test "x$cf_with_manpages" = xyes; then
3351 if test -d tack ; then
3352 if test -f $srcdir/$tack.h; then
3353 cat >> Makefile <<CF_EOF
3354
3355 install.man \\
3356 uninstall.man ::
3357         cd tack && \${MAKE} \${CF_MFLAGS} \[$]@
3358 CF_EOF
3359 fi
3360 fi
3361 fi
3362
3363 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3364 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3365 dnl anything, and will make it more standardized.  It's awkward to decide this
3366 dnl at configuration because of quoting, so we'll simply make all headers
3367 dnl installed via a script that can do the right thing.
3368
3369 rm -f headers.sed headers.sh
3370
3371 dnl ( generating this script makes the makefiles a little tidier :-)
3372 echo creating headers.sh
3373 cat >headers.sh <<CF_EOF
3374 #! /bin/sh
3375 # This shell script is generated by the 'configure' script.  It is invoked in a
3376 # subdirectory of the build tree.  It generates a sed-script in the parent
3377 # directory that is used to adjust includes for header files that reside in a
3378 # subdirectory of /usr/include, etc.
3379 PRG=""
3380 while test \[$]# != 3
3381 do
3382 PRG="\$PRG \[$]1"; shift
3383 done
3384 DST=\[$]1
3385 REF=\[$]2
3386 SRC=\[$]3
3387 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3388 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3389 echo installing \$SRC in \$DST
3390 CF_EOF
3391
3392 if test $WITH_CURSES_H = yes; then
3393         cat >>headers.sh <<CF_EOF
3394 case \$DST in
3395 /*/include/*)
3396         END=\`basename \$DST\`
3397         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3398         do
3399                 NAME=\`basename \$i\`
3400                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3401         done
3402         ;;
3403 *)
3404         echo "" >> \$TMPSED
3405         ;;
3406 esac
3407 CF_EOF
3408
3409 else
3410         cat >>headers.sh <<CF_EOF
3411 case \$DST in
3412 /*/include/*)
3413         END=\`basename \$DST\`
3414         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3415         do
3416                 NAME=\`basename \$i\`
3417                 if test "\$NAME" = "curses.h"
3418                 then
3419                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3420                         NAME=ncurses.h
3421                 fi
3422                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3423         done
3424         ;;
3425 *)
3426         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3427         ;;
3428 esac
3429 CF_EOF
3430 fi
3431 cat >>headers.sh <<CF_EOF
3432 rm -f \$TMPSRC
3433 sed -f \$TMPSED \$SRC > \$TMPSRC
3434 NAME=\`basename \$SRC\`
3435 CF_EOF
3436 if test $WITH_CURSES_H != yes; then
3437         cat >>headers.sh <<CF_EOF
3438 test "\$NAME" = "curses.h" && NAME=ncurses.h
3439 CF_EOF
3440 fi
3441 cat >>headers.sh <<CF_EOF
3442 # Just in case someone gzip'd manpages, remove the conflicting copy.
3443 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3444
3445 eval \$PRG \$TMPSRC \$DST/\$NAME
3446 rm -f \$TMPSRC \$TMPSED
3447 CF_EOF
3448
3449 chmod 0755 headers.sh
3450
3451 for cf_dir in $SRC_SUBDIRS
3452 do
3453         if test ! -d $srcdir/$cf_dir ; then
3454                 continue
3455         fi
3456
3457         if test -f $srcdir/$cf_dir/headers; then
3458                 $AWK -f $srcdir/mk-hdr.awk \
3459                         subset="$LIB_SUBSETS" \
3460                         compat="$WITH_CURSES_H" \
3461                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3462         fi
3463
3464         if test -f $srcdir/$cf_dir/modules; then
3465                 if test "$cf_dir" != "c++" ; then
3466                         cat >>$cf_dir/Makefile <<"CF_EOF"
3467 depend : ${AUTO_SRC}
3468         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3469
3470 # DO NOT DELETE THIS LINE -- make depend depends on it.
3471 CF_EOF
3472                 fi
3473         fi
3474 done
3475 AC_SUBST(LIBS_TO_MAKE)
3476 ])dnl
3477 dnl ---------------------------------------------------------------------------
3478 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3479 dnl -------------
3480 dnl Find the and soname for the given shared library.  Set the cache variable
3481 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3482 dnl variable to "unknown".
3483 dnl
3484 dnl $1 = headers
3485 dnl $2 = code
3486 dnl $3 = library name
3487 AC_DEFUN([CF_LIB_SONAME],
3488 [
3489 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3490
3491 cf_cv_$3_soname=unknown
3492 if test "$cross_compiling" != yes ; then
3493 cat >conftest.$ac_ext <<CF_EOF
3494 $1
3495 int main()
3496 {
3497 $2
3498         ${cf_cv_main_return:-return}(0);
3499 }
3500 CF_EOF
3501 cf_save_LIBS="$LIBS"
3502         CF_ADD_LIB($3)
3503         if AC_TRY_EVAL(ac_compile) ; then
3504                 if AC_TRY_EVAL(ac_link) ; then
3505                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3506                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3507                 fi
3508         fi
3509 rm -rf conftest*
3510 LIBS="$cf_save_LIBS"
3511 fi
3512 ])
3513 ])
3514 dnl ---------------------------------------------------------------------------
3515 dnl CF_LIB_SUFFIX version: 17 updated: 2011/07/02 15:36:04
3516 dnl -------------
3517 dnl Compute the library file-suffix from the given model name
3518 dnl $1 = model name
3519 dnl $2 = variable to set (the nominal library suffix)
3520 dnl $3 = dependency variable to set (actual filename)
3521 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3522 AC_DEFUN([CF_LIB_SUFFIX],
3523 [
3524         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3525         case $1 in #(vi
3526         libtool) #(vi
3527                 $2='.la'
3528                 $3=[$]$2
3529                 ;;
3530         normal) #(vi
3531                 $2='.a'
3532                 $3=[$]$2
3533                 ;;
3534         debug) #(vi
3535                 $2='_g.a'
3536                 $3=[$]$2
3537                 ;;
3538         profile) #(vi
3539                 $2='_p.a'
3540                 $3=[$]$2
3541                 ;;
3542         shared) #(vi
3543                 case $cf_cv_system_name in
3544                 aix[[5-7]]*) #(vi
3545                         $2='.a'
3546                         $3=[$]$2
3547                         ;;
3548                 cygwin*) #(vi
3549                         $2='.dll'
3550                         $3='.dll.a'
3551                         ;;
3552                 darwin*) #(vi
3553                         $2='.dylib'
3554                         $3=[$]$2
3555                         ;;
3556                 hpux*) #(vi
3557                         case $target in
3558                         ia64*) #(vi
3559                                 $2='.so'
3560                                 $3=[$]$2
3561                                 ;;
3562                         *) #(vi
3563                                 $2='.sl'
3564                                 $3=[$]$2
3565                                 ;;
3566                         esac
3567                         ;;
3568                 *)      $2='.so'
3569                         $3=[$]$2
3570                         ;;
3571                 esac
3572         esac
3573         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3574         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
3575 ])dnl
3576 dnl ---------------------------------------------------------------------------
3577 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
3578 dnl -----------
3579 dnl Compute the string to append to -library from the given model name
3580 dnl $1 = model name
3581 dnl $2 = variable to set
3582 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3583 AC_DEFUN([CF_LIB_TYPE],
3584 [
3585         case $1 in
3586         libtool) $2=''   ;;
3587         normal)  $2=''   ;;
3588         debug)   $2='_g' ;;
3589         profile) $2='_p' ;;
3590         shared)  $2=''   ;;
3591         esac
3592         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3593 ])dnl
3594 dnl ---------------------------------------------------------------------------
3595 dnl CF_LINK_DATAONLY version: 9 updated: 2009/01/01 20:21:38
3596 dnl ----------------
3597 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3598 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3599 dnl have to provide wrappers for global tables to ensure they're linked
3600 dnl properly.
3601 AC_DEFUN([CF_LINK_DATAONLY],
3602 [
3603 AC_MSG_CHECKING([if data-only library module links])
3604 AC_CACHE_VAL(cf_cv_link_dataonly,[
3605         rm -f conftest.a
3606         cat >conftest.$ac_ext <<EOF
3607 #line __oline__ "configure"
3608 int     testdata[[3]] = { 123, 456, 789 };
3609 EOF
3610         if AC_TRY_EVAL(ac_compile) ; then
3611                 mv conftest.o data.o && \
3612                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3613         fi
3614         rm -f conftest.$ac_ext data.o
3615         cat >conftest.$ac_ext <<EOF
3616 #line __oline__ "configure"
3617 int     testfunc()
3618 {
3619 #if defined(NeXT)
3620         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3621 #else
3622         extern int testdata[[3]];
3623         return testdata[[0]] == 123
3624            &&  testdata[[1]] == 456
3625            &&  testdata[[2]] == 789;
3626 #endif
3627 }
3628 EOF
3629         if AC_TRY_EVAL(ac_compile); then
3630                 mv conftest.o func.o && \
3631                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3632         fi
3633         rm -f conftest.$ac_ext func.o
3634         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3635         cf_saveLIBS="$LIBS"
3636         LIBS="conftest.a $LIBS"
3637         AC_TRY_RUN([
3638         int main()
3639         {
3640                 extern int testfunc();
3641                 ${cf_cv_main_return:-return} (!testfunc());
3642         }
3643         ],
3644         [cf_cv_link_dataonly=yes],
3645         [cf_cv_link_dataonly=no],
3646         [cf_cv_link_dataonly=unknown])
3647         LIBS="$cf_saveLIBS"
3648         ])
3649 AC_MSG_RESULT($cf_cv_link_dataonly)
3650
3651 if test "$cf_cv_link_dataonly" = no ; then
3652         AC_DEFINE(BROKEN_LINKER)
3653         BROKEN_LINKER=1
3654 fi
3655
3656 ])dnl
3657 dnl ---------------------------------------------------------------------------
3658 dnl CF_LINK_FUNCS version: 7 updated: 2006/12/16 12:33:30
3659 dnl -------------
3660 dnl Most Unix systems have both link and symlink, a few don't have symlink.
3661 dnl A few non-Unix systems implement symlink, but not link.
3662 dnl A few non-systems implement neither (or have nonfunctional versions).
3663 AC_DEFUN([CF_LINK_FUNCS],
3664 [
3665 AC_CHECK_FUNCS( \
3666         remove \
3667         unlink )
3668
3669 if test "$cross_compiling" = yes ; then
3670         AC_CHECK_FUNCS( \
3671                 link \
3672                 symlink )
3673 else
3674         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
3675                 cf_cv_link_funcs=
3676                 for cf_func in link symlink ; do
3677                         AC_TRY_RUN([
3678 #include <sys/types.h>
3679 #include <sys/stat.h>
3680 #ifdef HAVE_UNISTD_H
3681 #include <unistd.h>
3682 #endif
3683 int main()
3684 {
3685         int fail = 0;
3686         char *src = "config.log";
3687         char *dst = "conftest.chk";
3688         struct stat src_sb;
3689         struct stat dst_sb;
3690
3691         stat(src, &src_sb);
3692         fail = ($cf_func("config.log", "conftest.chk") < 0)
3693             || (stat(dst, &dst_sb) < 0)
3694             || (dst_sb.st_mtime != src_sb.st_mtime);
3695 #ifdef HAVE_UNLINK
3696         unlink(dst);
3697 #else
3698         remove(dst);
3699 #endif
3700         ${cf_cv_main_return:-return} (fail);
3701 }
3702                         ],[
3703                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
3704                         eval 'ac_cv_func_'$cf_func'=yes'],[
3705                         eval 'ac_cv_func_'$cf_func'=no'],[
3706                         eval 'ac_cv_func_'$cf_func'=error'])
3707                 done
3708                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
3709         ])
3710         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK)
3711         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK)
3712 fi
3713 ])dnl
3714 dnl ---------------------------------------------------------------------------
3715 dnl CF_MAIN_RETURN version: 1 updated: 2006/12/10 09:51:54
3716 dnl --------------
3717 dnl Check if a return from main to the shell actually returns the same exit
3718 dnl code.  This is true for almost any POSIX environment.
3719 dnl
3720 dnl Some very old environments did not flush stdout, etc., on an exit.  That
3721 dnl would be a useful case to test for also.
3722 AC_DEFUN([CF_MAIN_RETURN],
3723 [
3724 cf_cv_main_return=return
3725 ])dnl
3726 dnl ---------------------------------------------------------------------------
3727 dnl CF_MAKEFLAGS version: 14 updated: 2011/03/31 19:29:46
3728 dnl ------------
3729 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
3730 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
3731 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
3732 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
3733 AC_DEFUN([CF_MAKEFLAGS],
3734 [
3735 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
3736         cf_cv_makeflags=''
3737         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
3738         do
3739                 cat >cf_makeflags.tmp <<CF_EOF
3740 SHELL = /bin/sh
3741 all :
3742         @ echo '.$cf_option'
3743 CF_EOF
3744                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
3745                 case "$cf_result" in
3746                 .*k)
3747                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
3748                         case "$cf_result" in
3749                         .*CC=*) cf_cv_makeflags=
3750                                 ;;
3751                         *)      cf_cv_makeflags=$cf_option
3752                                 ;;
3753                         esac
3754                         break
3755                         ;;
3756                 .-)     ;;
3757                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
3758                         ;;
3759                 esac
3760         done
3761         rm -f cf_makeflags.tmp
3762 ])
3763
3764 AC_SUBST(cf_cv_makeflags)
3765 ])dnl
3766 dnl ---------------------------------------------------------------------------
3767 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
3768 dnl ------------
3769 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
3770 dnl a monocase filesystem.
3771 AC_DEFUN([CF_MAKE_TAGS],[
3772 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
3773
3774 AC_CHECK_PROGS(CTAGS, exctags ctags)
3775 AC_CHECK_PROGS(ETAGS, exetags etags)
3776
3777 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
3778
3779 if test "$cf_cv_mixedcase" = yes ; then
3780         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
3781 else
3782         MAKE_UPPER_TAGS=no
3783 fi
3784
3785 if test "$MAKE_UPPER_TAGS" = yes ; then
3786         MAKE_UPPER_TAGS=
3787 else
3788         MAKE_UPPER_TAGS="#"
3789 fi
3790
3791 if test "$MAKE_LOWER_TAGS" = yes ; then
3792         MAKE_LOWER_TAGS=
3793 else
3794         MAKE_LOWER_TAGS="#"
3795 fi
3796
3797 AC_SUBST(CTAGS)
3798 AC_SUBST(ETAGS)
3799
3800 AC_SUBST(MAKE_UPPER_TAGS)
3801 AC_SUBST(MAKE_LOWER_TAGS)
3802 ])dnl
3803 dnl ---------------------------------------------------------------------------
3804 dnl CF_MANPAGE_FORMAT version: 9 updated: 2010/10/23 16:10:30
3805 dnl -----------------
3806 dnl Option to allow user to override automatic configuration of manpage format.
3807 dnl There are several special cases:
3808 dnl
3809 dnl     gzip - man checks for, can display gzip'd files
3810 dnl     compress - man checks for, can display compressed files
3811 dnl     BSDI - files in the cat-directories are suffixed ".0"
3812 dnl     formatted - installer should format (put files in cat-directory)
3813 dnl     catonly - installer should only format, e.g., for a turnkey system.
3814 dnl
3815 dnl There are other configurations which this macro does not test, e.g., HPUX's
3816 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
3817 dnl convention would not match our use).
3818 AC_DEFUN([CF_MANPAGE_FORMAT],
3819 [
3820 AC_REQUIRE([CF_PATHSEP])
3821 AC_MSG_CHECKING(format of man-pages)
3822
3823 AC_ARG_WITH(manpage-format,
3824         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
3825                           optionally formatted/catonly, e.g., gzip,formatted],
3826         [MANPAGE_FORMAT=$withval],
3827         [MANPAGE_FORMAT=unknown])
3828
3829 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
3830 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
3831
3832 cf_unknown=
3833
3834 case $MANPAGE_FORMAT in
3835 unknown)
3836   if test -z "$MANPATH" ; then
3837     MANPATH="/usr/man:/usr/share/man"
3838   fi
3839
3840   # look for the 'date' man-page (it's most likely to be installed!)
3841   MANPAGE_FORMAT=
3842   cf_preform=no
3843   cf_catonly=yes
3844   cf_example=date
3845
3846   IFS="${IFS:-  }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
3847   for cf_dir in $MANPATH; do
3848     test -z "$cf_dir" && cf_dir=/usr/man
3849     for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
3850     do
3851       cf_test=`echo $cf_name | sed -e 's/*//'`
3852       if test "x$cf_test" = "x$cf_name" ; then
3853
3854         case "$cf_name" in
3855         *.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
3856         *.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
3857         *.0)    MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
3858         *)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
3859         esac
3860
3861         case "$cf_name" in
3862         $cf_dir/man*)
3863           cf_catonly=no
3864           ;;
3865         $cf_dir/cat*)
3866           cf_preform=yes
3867           ;;
3868         esac
3869         break
3870       fi
3871
3872       # if we found a match in either man* or cat*, stop looking
3873       if test -n "$MANPAGE_FORMAT" ; then
3874         cf_found=no
3875         test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
3876         test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
3877         case "$cf_name" in
3878         $cf_dir/cat*)
3879           cf_found=yes
3880           ;;
3881         esac
3882         test $cf_found=yes && break
3883       fi
3884     done
3885     # only check the first directory in $MANPATH where we find manpages
3886     if test -n "$MANPAGE_FORMAT" ; then
3887        break
3888     fi
3889   done
3890   # if we did not find the example, just assume it is normal
3891   test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
3892   IFS="$ac_save_ifs"
3893   ;;
3894 *)
3895   for cf_option in $MANPAGE_FORMAT; do
3896      case $cf_option in #(vi
3897      gzip|compress|BSDI|normal|formatted|catonly)
3898        ;;
3899      *)
3900        cf_unknown="$cf_unknown $cf_option"
3901        ;;
3902      esac
3903   done
3904   ;;
3905 esac
3906
3907 AC_MSG_RESULT($MANPAGE_FORMAT)
3908 if test -n "$cf_unknown" ; then
3909   AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
3910 fi
3911 ])dnl
3912 dnl ---------------------------------------------------------------------------
3913 dnl CF_MANPAGE_RENAMES version: 7 updated: 2005/06/18 18:51:57
3914 dnl ------------------
3915 dnl The Debian people have their own naming convention for manpages.  This
3916 dnl option lets us override the name of the file containing renaming, or
3917 dnl disable it altogether.
3918 AC_DEFUN([CF_MANPAGE_RENAMES],
3919 [
3920 AC_MSG_CHECKING(for manpage renaming)
3921
3922 AC_ARG_WITH(manpage-renames,
3923         [  --with-manpage-renames  specify manpage-renaming],
3924         [MANPAGE_RENAMES=$withval],
3925         [MANPAGE_RENAMES=yes])
3926
3927 case ".$MANPAGE_RENAMES" in #(vi
3928 .no) #(vi
3929   ;;
3930 .|.yes)
3931   # Debian 'man' program?
3932   if test -f /etc/debian_version ; then
3933     MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
3934   else
3935     MANPAGE_RENAMES=no
3936   fi
3937   ;;
3938 esac
3939
3940 if test "$MANPAGE_RENAMES" != no ; then
3941   if test -f $srcdir/man/$MANPAGE_RENAMES ; then
3942     MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
3943   elif test ! -f $MANPAGE_RENAMES ; then
3944     AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
3945   fi
3946
3947   test ! -d man && mkdir man
3948
3949   # Construct a sed-script to perform renaming within man-pages
3950   if test -n "$MANPAGE_RENAMES" ; then
3951     test ! -d man && mkdir man
3952     sh $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
3953   fi
3954 fi
3955
3956 AC_MSG_RESULT($MANPAGE_RENAMES)
3957 AC_SUBST(MANPAGE_RENAMES)
3958 ])dnl
3959 dnl ---------------------------------------------------------------------------
3960 dnl CF_MANPAGE_SYMLINKS version: 5 updated: 2010/07/24 17:12:40
3961 dnl -------------------
3962 dnl Some people expect each tool to make all aliases for manpages in the
3963 dnl man-directory.  This accommodates the older, less-capable implementations
3964 dnl of 'man', and is optional.
3965 AC_DEFUN([CF_MANPAGE_SYMLINKS],
3966 [
3967 AC_MSG_CHECKING(if manpage aliases will be installed)
3968
3969 AC_ARG_WITH(manpage-aliases,
3970         [  --with-manpage-aliases  specify manpage-aliases using .so],
3971         [MANPAGE_ALIASES=$withval],
3972         [MANPAGE_ALIASES=yes])
3973
3974 AC_MSG_RESULT($MANPAGE_ALIASES)
3975
3976 case "x$LN_S" in #(vi
3977 xln*) #(vi
3978         cf_use_symlinks=yes
3979         ;;
3980 *)
3981         cf_use_symlinks=no
3982         ;;
3983 esac
3984
3985 MANPAGE_SYMLINKS=no
3986 if test "$MANPAGE_ALIASES" = yes ; then
3987 AC_MSG_CHECKING(if manpage symlinks should be used)
3988
3989 AC_ARG_WITH(manpage-symlinks,
3990         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
3991         [MANPAGE_SYMLINKS=$withval],
3992         [MANPAGE_SYMLINKS=$cf_use_symlinks])
3993
3994 if test "$$cf_use_symlinks" = no; then
3995 if test "$MANPAGE_SYMLINKS" = yes ; then
3996         AC_MSG_WARN(cannot make symlinks, will use .so files)
3997         MANPAGE_SYMLINKS=no
3998 fi
3999 fi
4000
4001 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4002 fi
4003
4004 ])dnl
4005 dnl ---------------------------------------------------------------------------
4006 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4007 dnl --------------
4008 dnl This option causes manpages to be run through tbl(1) to generate tables
4009 dnl correctly.
4010 AC_DEFUN([CF_MANPAGE_TBL],
4011 [
4012 AC_MSG_CHECKING(for manpage tbl)
4013
4014 AC_ARG_WITH(manpage-tbl,
4015         [  --with-manpage-tbl      specify manpage processing with tbl],
4016         [MANPAGE_TBL=$withval],
4017         [MANPAGE_TBL=no])
4018
4019 AC_MSG_RESULT($MANPAGE_TBL)
4020 ])dnl
4021 dnl ---------------------------------------------------------------------------
4022 dnl CF_MAN_PAGES version: 40 updated: 2011/09/10 16:20:21
4023 dnl ------------
4024 dnl Try to determine if the man-pages on the system are compressed, and if
4025 dnl so, what format is used.  Use this information to construct a script that
4026 dnl will install man-pages.
4027 AC_DEFUN([CF_MAN_PAGES],
4028 [
4029 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4030 CF_MANPAGE_FORMAT
4031 CF_MANPAGE_RENAMES
4032 CF_MANPAGE_SYMLINKS
4033 CF_MANPAGE_TBL
4034
4035   if test "$prefix" = "NONE" ; then
4036      cf_prefix="$ac_default_prefix"
4037   else
4038      cf_prefix="$prefix"
4039   fi
4040
4041   case "$MANPAGE_FORMAT" in # (vi
4042   *catonly*) # (vi
4043     cf_format=yes
4044     cf_inboth=no
4045     ;;
4046   *formatted*) # (vi
4047     cf_format=yes
4048     cf_inboth=yes
4049     ;;
4050   *)
4051     cf_format=no
4052     cf_inboth=no
4053     ;;
4054   esac
4055
4056 test ! -d man && mkdir man
4057
4058 cf_so_strip=
4059 cf_compress=
4060 case "$MANPAGE_FORMAT" in #(vi
4061 *compress*) #(vi
4062         cf_so_strip="Z"
4063         cf_compress=compress
4064   ;;
4065 *gzip*)
4066         cf_so_strip="gz"
4067         cf_compress=gzip
4068   ;;
4069 esac
4070
4071 cf_edit_man=./edit_man.sh
4072 cf_man_alias=`pwd`/man_alias.sed
4073
4074 cat >$cf_edit_man <<CF_EOF
4075 #! /bin/sh
4076 # this script is generated by the configure-script CF_MAN_PAGES macro.
4077
4078 prefix="$cf_prefix"
4079 datadir="$datadir"
4080
4081 NCURSES_MAJOR="$NCURSES_MAJOR"
4082 NCURSES_MINOR="$NCURSES_MINOR"
4083 NCURSES_PATCH="$NCURSES_PATCH"
4084
4085 NCURSES_OSPEED="$NCURSES_OSPEED"
4086 TERMINFO="$TERMINFO"
4087
4088 INSTALL="$INSTALL"
4089 INSTALL_DATA="$INSTALL_DATA"
4090
4091 transform="$program_transform_name"
4092
4093 TMP=\${TMPDIR:=/tmp}/man\$\$
4094 trap "rm -f \$TMP" 0 1 2 5 15
4095
4096 form=\[$]1
4097 shift || exit 1
4098
4099 verb=\[$]1
4100 shift || exit 1
4101
4102 mandir=\[$]1
4103 shift || exit 1
4104
4105 srcdir=\[$]1
4106 top_srcdir=\[$]srcdir/..
4107 shift || exit 1
4108
4109 if test "\$form" = normal ; then
4110         if test "$cf_format" = yes ; then
4111         if test "$cf_inboth" = no ; then
4112                 sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4113                 exit $?
4114         fi
4115         fi
4116         cf_subdir=\$mandir/man
4117         cf_tables=$MANPAGE_TBL
4118 else
4119         cf_subdir=\$mandir/cat
4120         cf_tables=yes
4121 fi
4122
4123 # process the list of source-files
4124 for i in \[$]* ; do
4125 case \$i in #(vi
4126 *.orig|*.rej) ;; #(vi
4127 *.[[0-9]]*)
4128         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4129         if test \$verb = installing ; then
4130         if test ! -d \$cf_subdir\${section} ; then
4131                 mkdir -p \$cf_subdir\$section
4132         fi
4133         fi
4134
4135         # replace variables in man page
4136         if test ! -f $cf_man_alias ; then
4137 cat >>$cf_man_alias <<-CF_EOF2
4138                 s,@DATADIR@,\$datadir,g
4139                 s,@TERMINFO@,\$TERMINFO,g
4140                 s,@NCURSES_MAJOR@,\$NCURSES_MAJOR,g
4141                 s,@NCURSES_MINOR@,\$NCURSES_MINOR,g
4142                 s,@NCURSES_PATCH@,\$NCURSES_PATCH,g
4143                 s,@NCURSES_OSPEED@,\$NCURSES_OSPEED,g
4144 CF_EOF
4145         ifelse($1,,,[
4146         for cf_name in $1
4147         do
4148                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4149                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4150 cat >>$cf_edit_man <<-CF_EOF
4151                 s,@$cf_NAME@,$cf_name,g
4152 CF_EOF
4153         done
4154         ])
4155 cat >>$cf_edit_man <<CF_EOF
4156 CF_EOF2
4157                 echo "...made $cf_man_alias"
4158         fi
4159
4160         aliases=
4161         cf_source=\`basename \$i\`
4162         inalias=\$cf_source
4163         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4164         if test ! -f \$inalias ; then
4165                 echo .. skipped \$cf_source
4166                 continue
4167         fi
4168 CF_EOF
4169
4170 if test "$MANPAGE_ALIASES" != no ; then
4171 cat >>$cf_edit_man <<CF_EOF
4172         nCurses=ignore.3x
4173         test $with_curses_h = yes && nCurses=ncurses.3x
4174         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4175 CF_EOF
4176 fi
4177
4178 if test "$MANPAGE_RENAMES" = no ; then
4179 cat >>$cf_edit_man <<CF_EOF
4180         # perform program transformations for section 1 man pages
4181         if test \$section = 1 ; then
4182                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4183         else
4184                 cf_target=\$cf_subdir\${section}/\$cf_source
4185         fi
4186 CF_EOF
4187 else
4188 cat >>$cf_edit_man <<CF_EOF
4189         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4190         if test -z "\$cf_target" ; then
4191                 echo '? missing rename for '\$cf_source
4192                 cf_target="\$cf_source"
4193         fi
4194         cf_target="\$cf_subdir\${section}/\${cf_target}"
4195
4196 CF_EOF
4197 fi
4198
4199 cat >>$cf_edit_man <<CF_EOF
4200         sed     -f $cf_man_alias \\
4201 CF_EOF
4202
4203 if test -f $MANPAGE_RENAMES ; then
4204 cat >>$cf_edit_man <<CF_EOF
4205                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4206 CF_EOF
4207 else
4208 cat >>$cf_edit_man <<CF_EOF
4209                 < \$i >\$TMP
4210 CF_EOF
4211 fi
4212
4213 cat >>$cf_edit_man <<CF_EOF
4214 if test \$cf_tables = yes ; then
4215         tbl \$TMP >\$TMP.out
4216         mv \$TMP.out \$TMP
4217 fi
4218 CF_EOF
4219
4220 if test $with_overwrite != yes ; then
4221 cat >>$cf_edit_man <<CF_EOF
4222         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
4223         mv \$TMP.out \$TMP
4224 CF_EOF
4225 fi
4226
4227 if test $with_curses_h != yes ; then
4228 cat >>$cf_edit_man <<CF_EOF
4229         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4230         mv \$TMP.out \$TMP
4231 CF_EOF
4232 fi
4233
4234 cat >>$cf_edit_man <<CF_EOF
4235         if test \$form = format ; then
4236                 nroff -man \$TMP >\$TMP.out
4237                 mv \$TMP.out \$TMP
4238         fi
4239 CF_EOF
4240
4241 if test -n "$cf_compress" ; then
4242 cat >>$cf_edit_man <<CF_EOF
4243         if test \$verb = installing ; then
4244         if ( $cf_compress -f \$TMP )
4245         then
4246                 mv \$TMP.$cf_so_strip \$TMP
4247         fi
4248         fi
4249         cf_target="\$cf_target.$cf_so_strip"
4250 CF_EOF
4251 fi
4252
4253 case "$MANPAGE_FORMAT" in #(vi
4254 *BSDI*)
4255 cat >>$cf_edit_man <<CF_EOF
4256         if test \$form = format ; then
4257                 # BSDI installs only .0 suffixes in the cat directories
4258                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
4259         fi
4260 CF_EOF
4261   ;;
4262 esac
4263
4264 cat >>$cf_edit_man <<CF_EOF
4265         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
4266         if test \$verb = installing ; then
4267                 echo \$verb \$cf_target
4268                 \$INSTALL_DATA \$TMP \$cf_target
4269                 test -d \$cf_subdir\${section} &&
4270                 test -n "\$aliases" && (
4271                         cd \$cf_subdir\${section} && (
4272                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
4273                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
4274                                 cf_target=\`basename \$cf_target\`
4275                                 for cf_alias in \$aliases
4276                                 do
4277                                         if test \$section = 1 ; then
4278                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4279                                         fi
4280
4281                                         if test "$MANPAGE_SYMLINKS" = yes ; then
4282                                                 if test -f \$cf_alias\${suffix} ; then
4283                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
4284                                                         then
4285                                                                 continue
4286                                                         fi
4287                                                 fi
4288                                                 echo .. \$verb alias \$cf_alias\${suffix}
4289 CF_EOF
4290 case "x$LN_S" in #(vi
4291 *-f) #(vi
4292 cat >>$cf_edit_man <<CF_EOF
4293                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4294 CF_EOF
4295         ;;
4296 *)
4297 cat >>$cf_edit_man <<CF_EOF
4298                                                 rm -f \$cf_alias\${suffix}
4299                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4300 CF_EOF
4301         ;;
4302 esac
4303 cat >>$cf_edit_man <<CF_EOF
4304                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
4305                                                 echo ".so \$cf_source" >\$TMP
4306 CF_EOF
4307 if test -n "$cf_compress" ; then
4308 cat >>$cf_edit_man <<CF_EOF
4309                                                 if test -n "$cf_so_strip" ; then
4310                                                         $cf_compress -f \$TMP
4311                                                         mv \$TMP.$cf_so_strip \$TMP
4312                                                 fi
4313 CF_EOF
4314 fi
4315 cat >>$cf_edit_man <<CF_EOF
4316                                                 echo .. \$verb alias \$cf_alias\${suffix}
4317                                                 rm -f \$cf_alias\${suffix}
4318                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
4319                                         fi
4320                                 done
4321                         )
4322                 )
4323         elif test \$verb = removing ; then
4324                 test -f \$cf_target && (
4325                         echo \$verb \$cf_target
4326                         rm -f \$cf_target
4327                 )
4328                 test -d \$cf_subdir\${section} &&
4329                 test -n "\$aliases" && (
4330                         cd \$cf_subdir\${section} && (
4331                                 for cf_alias in \$aliases
4332                                 do
4333                                         if test \$section = 1 ; then
4334                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4335                                         fi
4336
4337                                         echo .. \$verb alias \$cf_alias\${suffix}
4338                                         rm -f \$cf_alias\${suffix}
4339                                 done
4340                         )
4341                 )
4342         else
4343 #               echo ".hy 0"
4344                 cat \$TMP
4345         fi
4346         ;;
4347 esac
4348 done
4349
4350 if test $cf_inboth = yes ; then
4351 if test \$form != format ; then
4352         sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4353 fi
4354 fi
4355
4356 exit 0
4357 CF_EOF
4358 chmod 755 $cf_edit_man
4359
4360 ])dnl
4361 dnl ---------------------------------------------------------------------------
4362 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
4363 dnl -----------
4364 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
4365 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
4366 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
4367 AC_DEFUN([CF_MATH_LIB],
4368 [
4369 AC_CACHE_CHECK(if -lm needed for math functions,
4370         cf_cv_need_libm,[
4371         AC_TRY_LINK([
4372         #include <stdio.h>
4373         #include <math.h>
4374         ],
4375         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
4376         [cf_cv_need_libm=no],
4377         [cf_cv_need_libm=yes])])
4378 if test "$cf_cv_need_libm" = yes
4379 then
4380 ifelse($1,,[
4381         CF_ADD_LIB(m)
4382 ],[$1=-lm])
4383 fi
4384 ])
4385 dnl ---------------------------------------------------------------------------
4386 dnl CF_MIXEDCASE_FILENAMES version: 3 updated: 2003/09/20 17:07:55
4387 dnl ----------------------
4388 dnl Check if the file-system supports mixed-case filenames.  If we're able to
4389 dnl create a lowercase name and see it as uppercase, it doesn't support that.
4390 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
4391 [
4392 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
4393 if test "$cross_compiling" = yes ; then
4394         case $target_alias in #(vi
4395         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-mingw32*|*-uwin*) #(vi
4396                 cf_cv_mixedcase=no
4397                 ;;
4398         *)
4399                 cf_cv_mixedcase=yes
4400                 ;;
4401         esac
4402 else
4403         rm -f conftest CONFTEST
4404         echo test >conftest
4405         if test -f CONFTEST ; then
4406                 cf_cv_mixedcase=no
4407         else
4408                 cf_cv_mixedcase=yes
4409         fi
4410         rm -f conftest CONFTEST
4411 fi
4412 ])
4413 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES)
4414 ])dnl
4415 dnl ---------------------------------------------------------------------------
4416 dnl CF_MKSTEMP version: 8 updated: 2012/02/13 20:34:56
4417 dnl ----------
4418 dnl Check for a working mkstemp.  This creates two files, checks that they are
4419 dnl successfully created and distinct (AmigaOS apparently fails on the last).
4420 AC_DEFUN([CF_MKSTEMP],[
4421 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
4422 rm -rf conftest*
4423 AC_TRY_RUN([
4424 #include <sys/types.h>
4425 #include <stdlib.h>
4426 #include <stdio.h>
4427 #include <string.h>
4428 #include <sys/stat.h>
4429 int main()
4430 {
4431         char *tmpl = "conftestXXXXXX";
4432         char name[2][80];
4433         int n;
4434         int result = 0;
4435         int fd;
4436         struct stat sb;
4437
4438         umask(077);
4439         for (n = 0; n < 2; ++n) {
4440                 strcpy(name[n], tmpl);
4441                 if ((fd = mkstemp(name[n])) >= 0) {
4442                         if (!strcmp(name[n], tmpl)
4443                          || stat(name[n], &sb) != 0
4444                          || (sb.st_mode & S_IFMT) != S_IFREG
4445                          || (sb.st_mode & 077) != 0) {
4446                                 result = 1;
4447                         }
4448                         close(fd);
4449                 }
4450         }
4451         if (result == 0
4452          && !strcmp(name[0], name[1]))
4453                 result = 1;
4454         ${cf_cv_main_return:-return}(result);
4455 }
4456 ],[cf_cv_func_mkstemp=yes
4457 ],[cf_cv_func_mkstemp=no
4458 ],[cf_cv_func_mkstemp=maybe])
4459 ])
4460 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
4461         AC_CHECK_FUNC(mkstemp)
4462 fi
4463 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
4464         AC_DEFINE(HAVE_MKSTEMP)
4465 fi
4466 ])dnl
4467 dnl ---------------------------------------------------------------------------
4468 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
4469 dnl ----------
4470 dnl Write a debug message to config.log, along with the line number in the
4471 dnl configure script.
4472 AC_DEFUN([CF_MSG_LOG],[
4473 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
4474 ])dnl
4475 dnl ---------------------------------------------------------------------------
4476 dnl CF_NCURSES_ABI_6 version: 1 updated: 2005/09/17 18:42:49
4477 dnl ----------------
4478 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
4479 dnl warn about this.
4480 AC_DEFUN([CF_NCURSES_ABI_6],[
4481 if test "${with_abi_version+set}" != set; then
4482         case $cf_cv_rel_version in
4483         5.*)
4484                 cf_cv_rel_version=6.0
4485                 cf_cv_abi_version=6
4486                 AC_MSG_WARN(Overriding ABI version to $cf_cv_abi_version)
4487                 ;;
4488         esac
4489 fi
4490 ])dnl
4491 dnl ---------------------------------------------------------------------------
4492 dnl CF_NO_LEAKS_OPTION version: 4 updated: 2006/12/16 14:24:05
4493 dnl ------------------
4494 dnl see CF_WITH_NO_LEAKS
4495 AC_DEFUN([CF_NO_LEAKS_OPTION],[
4496 AC_MSG_CHECKING(if you want to use $1 for testing)
4497 AC_ARG_WITH($1,
4498         [$2],
4499         [AC_DEFINE($3)ifelse([$4],,[
4500          $4
4501 ])
4502         : ${with_cflags:=-g}
4503         : ${with_no_leaks:=yes}
4504          with_$1=yes],
4505         [with_$1=])
4506 AC_MSG_RESULT(${with_$1:-no})
4507
4508 case .$with_cflags in #(vi
4509 .*-g*)
4510         case .$CFLAGS in #(vi
4511         .*-g*) #(vi
4512                 ;;
4513         *)
4514                 CF_ADD_CFLAGS([-g])
4515                 ;;
4516         esac
4517         ;;
4518 esac
4519 ])dnl
4520 dnl ---------------------------------------------------------------------------
4521 dnl CF_NUMBER_SYNTAX version: 1 updated: 2003/09/20 18:12:49
4522 dnl ----------------
4523 dnl Check if the given variable is a number.  If not, report an error.
4524 dnl $1 is the variable
4525 dnl $2 is the message
4526 AC_DEFUN([CF_NUMBER_SYNTAX],[
4527 if test -n "$1" ; then
4528   case $1 in #(vi
4529   [[0-9]]*) #(vi
4530         ;;
4531   *)
4532         AC_MSG_ERROR($2 is not a number: $1)
4533         ;;
4534   esac
4535 else
4536   AC_MSG_ERROR($2 value is empty)
4537 fi
4538 ])dnl
4539 dnl ---------------------------------------------------------------------------
4540 dnl CF_OBJ_SUBDIR version: 4 updated: 2002/02/23 20:38:31
4541 dnl -------------
4542 dnl Compute the object-directory name from the given model name
4543 AC_DEFUN([CF_OBJ_SUBDIR],
4544 [
4545         case $1 in
4546         libtool) $2='obj_lo'  ;;
4547         normal)  $2='objects' ;;
4548         debug)   $2='obj_g' ;;
4549         profile) $2='obj_p' ;;
4550         shared)
4551                 case $cf_cv_system_name in #(vi
4552                 cygwin) #(vi
4553                         $2='objects' ;;
4554                 *)
4555                         $2='obj_s' ;;
4556                 esac
4557         esac
4558 ])dnl
4559 dnl ---------------------------------------------------------------------------
4560 dnl CF_PATHSEP version: 5 updated: 2010/05/26 05:38:42
4561 dnl ----------
4562 dnl Provide a value for the $PATH and similar separator
4563 AC_DEFUN([CF_PATHSEP],
4564 [
4565         case $cf_cv_system_name in
4566         os2*)   PATH_SEPARATOR=';'  ;;
4567         *)      PATH_SEPARATOR=':'  ;;
4568         esac
4569 ifelse([$1],,,[$1=$PATH_SEPARATOR])
4570         AC_SUBST(PATH_SEPARATOR)
4571 ])dnl
4572 dnl ---------------------------------------------------------------------------
4573 dnl CF_PATH_SYNTAX version: 13 updated: 2010/05/26 05:38:42
4574 dnl --------------
4575 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
4576 dnl begins with one of the prefix/exec_prefix variables, and then again if the
4577 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
4578 dnl delayed evaluation of those symbols.
4579 AC_DEFUN([CF_PATH_SYNTAX],[
4580 if test "x$prefix" != xNONE; then
4581   cf_path_syntax="$prefix"
4582 else
4583   cf_path_syntax="$ac_default_prefix"
4584 fi
4585
4586 case ".[$]$1" in #(vi
4587 .\[$]\(*\)*|.\'*\'*) #(vi
4588   ;;
4589 ..|./*|.\\*) #(vi
4590   ;;
4591 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
4592   ;;
4593 .\[$]{*prefix}*) #(vi
4594   eval $1="[$]$1"
4595   case ".[$]$1" in #(vi
4596   .NONE/*)
4597     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4598     ;;
4599   esac
4600   ;; #(vi
4601 .no|.NONE/*)
4602   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4603   ;;
4604 *)
4605   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
4606   ;;
4607 esac
4608 ])dnl
4609 dnl ---------------------------------------------------------------------------
4610 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
4611 dnl -------------
4612 dnl Check for the package-config program, unless disabled by command-line.
4613 AC_DEFUN([CF_PKG_CONFIG],
4614 [
4615 AC_MSG_CHECKING(if you want to use pkg-config)
4616 AC_ARG_WITH(pkg-config,
4617         [  --with-pkg-config{=path} enable/disable use of pkg-config],
4618         [cf_pkg_config=$withval],
4619         [cf_pkg_config=yes])
4620 AC_MSG_RESULT($cf_pkg_config)
4621
4622 case $cf_pkg_config in #(vi
4623 no) #(vi
4624         PKG_CONFIG=none
4625         ;;
4626 yes) #(vi
4627         CF_ACVERSION_CHECK(2.52,
4628                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
4629                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
4630         ;;
4631 *)
4632         PKG_CONFIG=$withval
4633         ;;
4634 esac
4635
4636 test -z "$PKG_CONFIG" && PKG_CONFIG=none
4637 if test "$PKG_CONFIG" != none ; then
4638         CF_PATH_SYNTAX(PKG_CONFIG)
4639 fi
4640
4641 AC_SUBST(PKG_CONFIG)
4642 ])dnl
4643 dnl ---------------------------------------------------------------------------
4644 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
4645 dnl -----------------
4646 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
4647 dnl
4648 dnl     POSIX.1-1990                            _POSIX_SOURCE
4649 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
4650 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
4651 dnl             Bindings Option
4652 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
4653 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
4654 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
4655 dnl
4656 dnl Parameters:
4657 dnl     $1 is the nominal value for _POSIX_C_SOURCE
4658 AC_DEFUN([CF_POSIX_C_SOURCE],
4659 [
4660 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
4661
4662 cf_save_CFLAGS="$CFLAGS"
4663 cf_save_CPPFLAGS="$CPPFLAGS"
4664
4665 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
4666 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
4667
4668 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
4669         CF_MSG_LOG(if the symbol is already defined go no further)
4670         AC_TRY_COMPILE([#include <sys/types.h>],[
4671 #ifndef _POSIX_C_SOURCE
4672 make an error
4673 #endif],
4674         [cf_cv_posix_c_source=no],
4675         [cf_want_posix_source=no
4676          case .$cf_POSIX_C_SOURCE in #(vi
4677          .[[12]]??*) #(vi
4678                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4679                 ;;
4680          .2) #(vi
4681                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4682                 cf_want_posix_source=yes
4683                 ;;
4684          .*)
4685                 cf_want_posix_source=yes
4686                 ;;
4687          esac
4688          if test "$cf_want_posix_source" = yes ; then
4689                 AC_TRY_COMPILE([#include <sys/types.h>],[
4690 #ifdef _POSIX_SOURCE
4691 make an error
4692 #endif],[],
4693                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
4694          fi
4695          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
4696          CFLAGS="$cf_trim_CFLAGS"
4697          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
4698          CF_MSG_LOG(if the second compile does not leave our definition intact error)
4699          AC_TRY_COMPILE([#include <sys/types.h>],[
4700 #ifndef _POSIX_C_SOURCE
4701 make an error
4702 #endif],,
4703          [cf_cv_posix_c_source=no])
4704          CFLAGS="$cf_save_CFLAGS"
4705          CPPFLAGS="$cf_save_CPPFLAGS"
4706         ])
4707 ])
4708
4709 if test "$cf_cv_posix_c_source" != no ; then
4710         CFLAGS="$cf_trim_CFLAGS"
4711         CPPFLAGS="$cf_trim_CPPFLAGS"
4712         CF_ADD_CFLAGS($cf_cv_posix_c_source)
4713 fi
4714
4715 ])dnl
4716 dnl ---------------------------------------------------------------------------
4717 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
4718 dnl ------------
4719 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
4720 dnl
4721 dnl $1 = symbol to test
4722 dnl $2 = value (if any) to use for a predefinition
4723 AC_DEFUN([CF_PREDEFINE],
4724 [
4725 AC_MSG_CHECKING(if we must define $1)
4726 AC_TRY_COMPILE([#include <sys/types.h>
4727 ],[
4728 #ifndef $1
4729 make an error
4730 #endif],[cf_result=no],[cf_result=yes])
4731 AC_MSG_RESULT($cf_result)
4732
4733 if test "$cf_result" = yes ; then
4734         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
4735 elif test "x$2" != "x" ; then
4736         AC_MSG_CHECKING(checking for compatible value versus $2)
4737         AC_TRY_COMPILE([#include <sys/types.h>
4738 ],[
4739 #if $1-$2 < 0
4740 make an error
4741 #endif],[cf_result=yes],[cf_result=no])
4742         AC_MSG_RESULT($cf_result)
4743         if test "$cf_result" = no ; then
4744                 # perhaps we can override it - try...
4745                 CPPFLAGS="$CPPFLAGS -D$1=$2"
4746         fi
4747 fi
4748 ])dnl
4749 dnl ---------------------------------------------------------------------------
4750 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
4751 dnl ------------
4752 dnl Append definitions and rules for the given programs to the subdirectory
4753 dnl Makefiles, and the recursion rule for the top-level Makefile.
4754 dnl
4755 dnl parameters
4756 dnl     $1 = script to run
4757 dnl     $2 = list of subdirectories
4758 dnl
4759 dnl variables
4760 dnl     $AWK
4761 AC_DEFUN([CF_PRG_RULES],
4762 [
4763 for cf_dir in $2
4764 do
4765         if test ! -d $srcdir/$cf_dir; then
4766                 continue
4767         elif test -f $srcdir/$cf_dir/programs; then
4768                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
4769         fi
4770 done
4771
4772 ])dnl
4773 dnl ---------------------------------------------------------------------------
4774 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
4775 dnl ----------
4776 dnl Check for archiver "ar".
4777 AC_DEFUN([CF_PROG_AR],[
4778 AC_CHECK_TOOL(AR, ar, ar)
4779 ])
4780 dnl ---------------------------------------------------------------------------
4781 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
4782 dnl -----------
4783 dnl Check for awk, ensure that the check found something.
4784 AC_DEFUN([CF_PROG_AWK],
4785 [
4786 AC_PROG_AWK
4787 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
4788 ])dnl
4789 dnl ---------------------------------------------------------------------------
4790 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
4791 dnl --------------
4792 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
4793 dnl the output file can be renamed, and allows for a shell variable that can
4794 dnl be used later.  The parameter is either CC or CXX.  The result is the
4795 dnl cache variable:
4796 dnl     $cf_cv_prog_CC_c_o
4797 dnl     $cf_cv_prog_CXX_c_o
4798 AC_DEFUN([CF_PROG_CC_C_O],
4799 [AC_REQUIRE([AC_PROG_CC])dnl
4800 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
4801 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
4802 [
4803 cat > conftest.$ac_ext <<CF_EOF
4804 #include <stdio.h>
4805 int main()
4806 {
4807         ${cf_cv_main_return:-return}(0);
4808 }
4809 CF_EOF
4810 # We do the test twice because some compilers refuse to overwrite an
4811 # existing .o file with -o, though they will create one.
4812 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
4813 if AC_TRY_EVAL(ac_try) &&
4814   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
4815 then
4816   eval cf_cv_prog_$1_c_o=yes
4817 else
4818   eval cf_cv_prog_$1_c_o=no
4819 fi
4820 rm -rf conftest*
4821 ])dnl
4822 if test $cf_cv_prog_$1_c_o = yes; then
4823   AC_MSG_RESULT([yes])
4824 else
4825   AC_MSG_RESULT([no])
4826 fi
4827 ])dnl
4828 dnl ---------------------------------------------------------------------------
4829 dnl CF_PROG_CC_U_D version: 1 updated: 2005/07/14 16:59:30
4830 dnl --------------
4831 dnl Check if C (preprocessor) -U and -D options are processed in the order
4832 dnl given rather than by type of option.  Some compilers insist on apply all
4833 dnl of the -U options after all of the -D options.  Others allow mixing them,
4834 dnl and may predefine symbols that conflict with those we define.
4835 AC_DEFUN([CF_PROG_CC_U_D],
4836 [
4837 AC_CACHE_CHECK(if $CC -U and -D options work together,cf_cv_cc_u_d_options,[
4838         cf_save_CPPFLAGS="$CPPFLAGS"
4839         CPPFLAGS="-UU_D_OPTIONS -DU_D_OPTIONS -DD_U_OPTIONS -UD_U_OPTIONS"
4840         AC_TRY_COMPILE([],[
4841 #ifndef U_D_OPTIONS
4842 make an undefined-error
4843 #endif
4844 #ifdef  D_U_OPTIONS
4845 make a defined-error
4846 #endif
4847         ],[
4848         cf_cv_cc_u_d_options=yes],[
4849         cf_cv_cc_u_d_options=no])
4850         CPPFLAGS="$cf_save_CPPFLAGS"
4851 ])
4852 ])dnl
4853 dnl ---------------------------------------------------------------------------
4854 dnl CF_PROG_EGREP version: 1 updated: 2006/09/16 11:40:59
4855 dnl -------------
4856 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
4857 dnl This macro adds a check to ensure the script found something.
4858 AC_DEFUN([CF_PROG_EGREP],
4859 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
4860    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
4861     then ac_cv_prog_egrep='grep -E'
4862     else ac_cv_prog_egrep='egrep'
4863     fi])
4864  EGREP=$ac_cv_prog_egrep
4865  AC_SUBST([EGREP])
4866 test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
4867 ])dnl
4868 dnl ---------------------------------------------------------------------------
4869 dnl CF_PROG_EXT version: 10 updated: 2004/01/03 19:28:18
4870 dnl -----------
4871 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
4872 AC_DEFUN([CF_PROG_EXT],
4873 [
4874 AC_REQUIRE([CF_CHECK_CACHE])
4875 case $cf_cv_system_name in
4876 os2*)
4877     CFLAGS="$CFLAGS -Zmt"
4878     CPPFLAGS="$CPPFLAGS -D__ST_MT_ERRNO__"
4879     CXXFLAGS="$CXXFLAGS -Zmt"
4880     # autoconf's macro sets -Zexe and suffix both, which conflict:w
4881     LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
4882     ac_cv_exeext=.exe
4883     ;;
4884 esac
4885
4886 AC_EXEEXT
4887 AC_OBJEXT
4888
4889 PROG_EXT="$EXEEXT"
4890 AC_SUBST(PROG_EXT)
4891 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT")
4892 ])dnl
4893 dnl ---------------------------------------------------------------------------
4894 dnl CF_PROG_GNAT version: 2 updated: 2011/10/22 14:01:47
4895 dnl ------------
4896 dnl Check for gnatmake, ensure that it is complete.
4897 AC_DEFUN([CF_PROG_GNAT],[
4898 cf_ada_make=gnatmake
4899 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
4900 if test "$ac_cv_prog_gnat_exists" = no; then
4901    cf_ada_make=
4902    cf_cv_prog_gnat_correct=no
4903 else
4904    CF_GNAT_VERSION
4905    AC_CHECK_PROG(M4_exists, m4, yes, no)
4906    if test "$ac_cv_prog_M4_exists" = no; then
4907       cf_cv_prog_gnat_correct=no
4908       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
4909    fi
4910    if test "$cf_cv_prog_gnat_correct" = yes; then
4911       AC_MSG_CHECKING(if GNAT works)
4912       CF_GNAT_TRY_RUN([procedure conftest;],
4913 [with Text_IO;
4914 with GNAT.OS_Lib;
4915 procedure conftest is
4916 begin
4917    Text_IO.Put ("Hello World");
4918    Text_IO.New_Line;
4919    GNAT.OS_Lib.OS_Exit (0);
4920 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
4921       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
4922    fi
4923 fi
4924
4925 AC_SUBST(cf_ada_make)
4926 ])dnl
4927 dnl ---------------------------------------------------------------------------
4928 dnl CF_PROG_INSTALL version: 5 updated: 2002/12/21 22:46:07
4929 dnl ---------------
4930 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
4931 dnl misc/tabset install won't work properly.  Usually this happens only when
4932 dnl using the fallback mkinstalldirs script
4933 AC_DEFUN([CF_PROG_INSTALL],
4934 [AC_PROG_INSTALL
4935 case $INSTALL in
4936 /*)
4937   ;;
4938 *)
4939   CF_DIRNAME(cf_dir,$INSTALL)
4940   test -z "$cf_dir" && cf_dir=.
4941   INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
4942   ;;
4943 esac
4944 ])dnl
4945 dnl ---------------------------------------------------------------------------
4946 dnl CF_PROG_LDCONFIG version: 3 updated: 2011/06/04 20:09:13
4947 dnl ----------------
4948 dnl Check for ldconfig, needed to fixup shared libraries that would be built
4949 dnl and then used in the install.
4950 AC_DEFUN([CF_PROG_LDCONFIG],[
4951 if test "$cross_compiling" = yes ; then
4952   LDCONFIG=:
4953 else
4954 case "$cf_cv_system_name" in #(vi
4955 dragonfly*|mirbsd*|freebsd*) #(vi
4956   test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
4957   ;;
4958 *) LDPATH=$PATH:/sbin:/usr/sbin
4959   AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
4960   ;;
4961 esac
4962 fi
4963 AC_SUBST(LDCONFIG)
4964 ])dnl
4965 dnl ---------------------------------------------------------------------------
4966 dnl CF_PROG_LINT version: 2 updated: 2009/08/12 04:43:14
4967 dnl ------------
4968 AC_DEFUN([CF_PROG_LINT],
4969 [
4970 AC_CHECK_PROGS(LINT, tdlint lint alint splint lclint)
4971 AC_SUBST(LINT_OPTS)
4972 ])dnl
4973 dnl ---------------------------------------------------------------------------
4974 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
4975 dnl ------------
4976 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
4977 dnl option if it is supported.
4978 AC_DEFUN([CF_PROG_LN_S],[
4979 AC_PROG_LN_S
4980 AC_MSG_CHECKING(if $LN_S -f options work)
4981
4982 rm -f conf$$.src conf$$dst
4983 echo >conf$$.dst
4984 echo first >conf$$.src
4985 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
4986         cf_prog_ln_sf=yes
4987 else
4988         cf_prog_ln_sf=no
4989 fi
4990 rm -f conf$$.dst conf$$src
4991 AC_MSG_RESULT($cf_prog_ln_sf)
4992
4993 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
4994 ])dnl
4995 dnl ---------------------------------------------------------------------------
4996 dnl CF_REGEX version: 9 updated: 2012/01/07 15:08:24
4997 dnl --------
4998 dnl Attempt to determine if we've got one of the flavors of regular-expression
4999 dnl code that we can support.
5000 AC_DEFUN([CF_REGEX],
5001 [
5002
5003 cf_regex_func=no
5004
5005 cf_regex_libs="regex re"
5006 case $host_os in #(vi
5007 mingw*)
5008         cf_regex_libs="gnurx $cf_regex_libs"
5009         ;;
5010 esac
5011
5012 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
5013         for cf_regex_lib in $cf_regex_libs
5014         do
5015                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
5016                                 CF_ADD_LIB($cf_regex_lib)
5017                                 cf_regex_func=regcomp
5018                                 break])
5019         done
5020 ])
5021
5022 if test "$cf_regex_func" = no ; then
5023         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
5024                 AC_CHECK_LIB(gen,compile,[
5025                                 CF_ADD_LIB(gen)
5026                                 cf_regex_func=compile])])
5027 fi
5028
5029 if test "$cf_regex_func" = no ; then
5030         AC_MSG_WARN(cannot find regular expression library)
5031 fi
5032
5033 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
5034
5035 cf_cv_regex_hdrs=no
5036 case $cf_regex_func in #(vi
5037 compile) #(vi
5038         for cf_regex_hdr in regexp.h regexpr.h
5039         do
5040                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
5041                         char *p = compile("", "", "", 0);
5042                         int x = step("", "");
5043                 ],[
5044                         cf_cv_regex_hdrs=$cf_regex_hdr
5045                         break
5046                 ])
5047         done
5048         ;;
5049 *)
5050         for cf_regex_hdr in regex.h
5051         do
5052                 AC_TRY_LINK([#include <sys/types.h>
5053 #include <$cf_regex_hdr>],[
5054                         regex_t *p;
5055                         int x = regcomp(p, "", 0);
5056                         int y = regexec(p, "", 0, 0, 0);
5057                         regfree(p);
5058                 ],[
5059                         cf_cv_regex_hdrs=$cf_regex_hdr
5060                         break
5061                 ])
5062         done
5063         ;;
5064 esac
5065
5066 ])
5067
5068 case $cf_cv_regex_hdrs in #(vi
5069     no)        AC_MSG_WARN(no regular expression header found) ;; #(vi
5070     regex.h)   AC_DEFINE(HAVE_REGEX_H_FUNCS) ;; #(vi
5071     regexp.h)  AC_DEFINE(HAVE_REGEXP_H_FUNCS) ;; #(vi
5072     regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS) ;;
5073 esac
5074 ])dnl
5075 dnl ---------------------------------------------------------------------------
5076 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
5077 dnl ----------------
5078 dnl Remove all -U and -D options that refer to the given symbol from a list
5079 dnl of C compiler options.  This works around the problem that not all
5080 dnl compilers process -U and -D options from left-to-right, so a -U option
5081 dnl cannot be used to cancel the effect of a preceding -D option.
5082 dnl
5083 dnl $1 = target (which could be the same as the source variable)
5084 dnl $2 = source (including '$')
5085 dnl $3 = symbol to remove
5086 define([CF_REMOVE_DEFINE],
5087 [
5088 $1=`echo "$2" | \
5089         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
5090                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
5091 ])dnl
5092 dnl ---------------------------------------------------------------------------
5093 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
5094 dnl -------------
5095 dnl Remove the given library from the symbol
5096 dnl
5097 dnl $1 = target (which could be the same as the source variable)
5098 dnl $2 = source (including '$')
5099 dnl $3 = library to remove
5100 define([CF_REMOVE_LIB],
5101 [
5102 # remove $3 library from $2
5103 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5104 ])dnl
5105 dnl ---------------------------------------------------------------------------
5106 dnl CF_RPATH_HACK version: 9 updated: 2011/02/13 13:31:33
5107 dnl -------------
5108 AC_DEFUN([CF_RPATH_HACK],
5109 [
5110 AC_REQUIRE([CF_LD_RPATH_OPT])
5111 AC_MSG_CHECKING(for updated LDFLAGS)
5112 if test -n "$LD_RPATH_OPT" ; then
5113         AC_MSG_RESULT(maybe)
5114
5115         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5116         cf_rpath_list="/usr/lib /lib"
5117         if test "$cf_ldd_prog" != no
5118         then
5119                 cf_rpath_oops=
5120
5121 AC_TRY_LINK([#include <stdio.h>],
5122                 [printf("Hello");],
5123                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort -u`
5124                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort -u`])
5125
5126                 # If we passed the link-test, but get a "not found" on a given library,
5127                 # this could be due to inept reconfiguration of gcc to make it only
5128                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
5129                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
5130                 # /usr/local libraries.
5131                 if test -n "$cf_rpath_oops"
5132                 then
5133                         for cf_rpath_src in $cf_rpath_oops
5134                         do
5135                                 for cf_rpath_dir in \
5136                                         /usr/local \
5137                                         /usr/pkg \
5138                                         /opt/sfw
5139                                 do
5140                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
5141                                         then
5142                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
5143                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
5144                                                 break
5145                                         fi
5146                                 done
5147                         done
5148                 fi
5149         fi
5150
5151         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5152
5153         CF_RPATH_HACK_2(LDFLAGS)
5154         CF_RPATH_HACK_2(LIBS)
5155
5156         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5157 fi
5158 AC_SUBST(EXTRA_LDFLAGS)
5159 ])dnl
5160 dnl ---------------------------------------------------------------------------
5161 dnl CF_RPATH_HACK_2 version: 6 updated: 2010/04/17 16:31:24
5162 dnl ---------------
5163 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
5164 dnl EXTRA_LDFLAGS for each -L option found.
5165 dnl
5166 dnl $cf_rpath_list contains a list of directories to ignore.
5167 dnl
5168 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
5169 dnl      but LIBS often has misplaced -L options.
5170 AC_DEFUN([CF_RPATH_HACK_2],
5171 [
5172 CF_VERBOSE(...checking $1 [$]$1)
5173
5174 cf_rpath_dst=
5175 for cf_rpath_src in [$]$1
5176 do
5177         case $cf_rpath_src in #(vi
5178         -L*) #(vi
5179
5180                 # check if this refers to a directory which we will ignore
5181                 cf_rpath_skip=no
5182                 if test -n "$cf_rpath_list"
5183                 then
5184                         for cf_rpath_item in $cf_rpath_list
5185                         do
5186                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
5187                                 then
5188                                         cf_rpath_skip=yes
5189                                         break
5190                                 fi
5191                         done
5192                 fi
5193
5194                 if test "$cf_rpath_skip" = no
5195                 then
5196                         # transform the option
5197                         if test "$LD_RPATH_OPT" = "-R " ; then
5198                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
5199                         else
5200                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
5201                         fi
5202
5203                         # if we have not already added this, add it now
5204                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
5205                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
5206                         then
5207                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
5208                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
5209                         fi
5210                 fi
5211                 ;;
5212         esac
5213         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
5214 done
5215 $1=$cf_rpath_dst
5216
5217 CF_VERBOSE(...checked $1 [$]$1)
5218 AC_SUBST(EXTRA_LDFLAGS)
5219 ])dnl
5220 dnl ---------------------------------------------------------------------------
5221 dnl CF_SHARED_OPTS version: 69 updated: 2011/07/30 19:31:39
5222 dnl --------------
5223 dnl --------------
5224 dnl Attempt to determine the appropriate CC/LD options for creating a shared
5225 dnl library.
5226 dnl
5227 dnl Note: ${LOCAL_LDFLAGS} is used to link executables that will run within the
5228 dnl build-tree, i.e., by making use of the libraries that are compiled in ../lib
5229 dnl We avoid compiling-in a ../lib path for the shared library since that can
5230 dnl lead to unexpected results at runtime.
5231 dnl ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared libraries
5232 dnl are compiled in ../../lib
5233 dnl
5234 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
5235 dnl to install symbolic links to the rel/abi versions of shared libraries.
5236 dnl
5237 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
5238 dnl version when making symbolic links.
5239 dnl
5240 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
5241 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
5242 dnl (ex: libncurses.so.<ver>).
5243 dnl
5244 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
5245 AC_DEFUN([CF_SHARED_OPTS],
5246 [
5247         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
5248         AC_REQUIRE([CF_LD_RPATH_OPT])
5249         LOCAL_LDFLAGS=
5250         LOCAL_LDFLAGS2=
5251         LD_SHARED_OPTS=
5252         INSTALL_LIB="-m 644"
5253
5254         cf_cv_do_symlinks=no
5255         cf_ld_rpath_opt=
5256         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
5257
5258         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
5259         AC_ARG_WITH(shlib-version,
5260         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
5261         [test -z "$withval" && withval=auto
5262         case $withval in #(vi
5263         yes) #(vi
5264                 cf_cv_shlib_version=auto
5265                 ;;
5266         rel|abi|auto|no) #(vi
5267                 cf_cv_shlib_version=$withval
5268                 ;;
5269         *)
5270                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
5271                 ;;
5272         esac
5273         ],[cf_cv_shlib_version=auto])
5274         AC_MSG_RESULT($cf_cv_shlib_version)
5275
5276         cf_cv_rm_so_locs=no
5277
5278         # Some less-capable ports of gcc support only -fpic
5279         CC_SHARED_OPTS=
5280         if test "$GCC" = yes
5281         then
5282                 AC_MSG_CHECKING(which $CC option to use)
5283                 cf_save_CFLAGS="$CFLAGS"
5284                 for CC_SHARED_OPTS in -fPIC -fpic ''
5285                 do
5286                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
5287                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
5288                 done
5289                 AC_MSG_RESULT($CC_SHARED_OPTS)
5290                 CFLAGS="$cf_save_CFLAGS"
5291         fi
5292
5293         cf_cv_shlib_version_infix=no
5294
5295         case $cf_cv_system_name in #(vi
5296         aix4.[3-9]*|aix[[5-7]]*) #(vi
5297                 if test "$GCC" = yes; then
5298                         CC_SHARED_OPTS=
5299                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5300                 else
5301                         # CC_SHARED_OPTS='-qpic=large -G'
5302                         # perhaps "-bM:SRE -bnoentry -bexpall"
5303                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5304                 fi
5305                 ;;
5306         beos*) #(vi
5307                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
5308                 ;;
5309         cygwin*) #(vi
5310                 CC_SHARED_OPTS=
5311                 MK_SHARED_LIB='sh ../mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5312                 cf_cv_shlib_version=cygdll
5313                 cf_cv_shlib_version_infix=cygdll
5314                 cat >mk_shared_lib.sh <<-CF_EOF
5315                 #!/bin/sh
5316                 SHARED_LIB=\[$]1
5317                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5318                 shift
5319                 cat <<-EOF
5320                 Linking shared library
5321                 ** SHARED_LIB \[$]SHARED_LIB
5322                 ** IMPORT_LIB \[$]IMPORT_LIB
5323 EOF
5324                 exec \[$]* -shared -Wl,--out-implib=../lib/\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o ../lib/\[$]{SHARED_LIB}
5325 CF_EOF
5326                 chmod +x mk_shared_lib.sh
5327                 ;;
5328         darwin*) #(vi
5329                 EXTRA_CFLAGS="-no-cpp-precomp"
5330                 CC_SHARED_OPTS="-dynamic"
5331                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
5332                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
5333                 cf_cv_shlib_version_infix=yes
5334                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
5335                         cf_save_LDFLAGS=$LDFLAGS
5336                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5337                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
5338                                 LDFLAGS=$cf_save_LDFLAGS])
5339                 if test $cf_cv_ldflags_search_paths_first = yes; then
5340                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5341                 fi
5342                 ;;
5343         hpux*) #(vi
5344                 # (tested with gcc 2.7.2 -- I don't have c89)
5345                 if test "$GCC" = yes; then
5346                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
5347                 else
5348                         CC_SHARED_OPTS='+Z'
5349                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
5350                 fi
5351                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
5352                 # HP-UX shared libraries must be executable, and should be
5353                 # readonly to exploit a quirk in the memory manager.
5354                 INSTALL_LIB="-m 555"
5355                 ;;
5356         interix*)
5357                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5358                 if test "$cf_cv_shlib_version" = rel; then
5359                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
5360                 else
5361                         cf_shared_soname='`basename $@`'
5362                 fi
5363                 CC_SHARED_OPTS=
5364                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
5365                 ;;
5366         irix*) #(vi
5367                 if test "$cf_cv_enable_rpath" = yes ; then
5368                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5369                 fi
5370                 # tested with IRIX 5.2 and 'cc'.
5371                 if test "$GCC" != yes; then
5372                         CC_SHARED_OPTS='-KPIC'
5373                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
5374                 else
5375                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
5376                 fi
5377                 cf_cv_rm_so_locs=yes
5378                 ;;
5379         linux*|gnu*|k*bsd*-gnu) #(vi
5380                 if test "$DFT_LWR_MODEL" = "shared" ; then
5381                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5382                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5383                 fi
5384                 if test "$cf_cv_enable_rpath" = yes ; then
5385                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5386                 fi
5387                 CF_SHARED_SONAME
5388                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5389                 ;;
5390         openbsd[[2-9]].*|mirbsd*) #(vi
5391                 if test "$DFT_LWR_MODEL" = "shared" ; then
5392                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5393                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5394                 fi
5395                 if test "$cf_cv_enable_rpath" = yes ; then
5396                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5397                 fi
5398                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5399                 CF_SHARED_SONAME
5400                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5401                 ;;
5402         nto-qnx*|openbsd*|freebsd[[12]].*) #(vi
5403                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5404                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
5405                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5406                 ;;
5407         dragonfly*|freebsd*) #(vi
5408                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5409                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5410                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5411                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
5412                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5413                 fi
5414                 CF_SHARED_SONAME
5415                 MK_SHARED_LIB='${LD} -shared -Bshareable -soname=`basename $[@]` -o $[@]'
5416                 ;;
5417         netbsd*) #(vi
5418                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5419                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5420                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5421                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5422                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5423                         if test "$cf_cv_shlib_version" = auto; then
5424                         if test -f /usr/libexec/ld.elf_so; then
5425                                 cf_cv_shlib_version=abi
5426                         else
5427                                 cf_cv_shlib_version=rel
5428                         fi
5429                         fi
5430                         CF_SHARED_SONAME
5431                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
5432                 else
5433                         MK_SHARED_LIB='${LD} -shared -Bshareable -o $[@]'
5434                 fi
5435                 ;;
5436         osf*|mls+*) #(vi
5437                 # tested with OSF/1 V3.2 and 'cc'
5438                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
5439                 # link with shared libs).
5440                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
5441                 case $host_os in #(vi
5442                 osf4*)
5443                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
5444                         ;;
5445                 esac
5446                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
5447                 if test "$DFT_LWR_MODEL" = "shared" ; then
5448                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5449                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5450                 fi
5451                 cf_cv_rm_so_locs=yes
5452                 ;;
5453         sco3.2v5*)  # (also uw2* and UW7: hops 13-Apr-98
5454                 # tested with osr5.0.5
5455                 if test "$GCC" != yes; then
5456                         CC_SHARED_OPTS='-belf -KPIC'
5457                 fi
5458                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
5459                 if test "$cf_cv_enable_rpath" = yes ; then
5460                         # only way is to set LD_RUN_PATH but no switch for it
5461                         RUN_PATH=$libdir
5462                 fi
5463                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5464                 LINK_PROGS='LD_RUN_PATH=${libdir}'
5465                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
5466                 ;;
5467         sunos4*) #(vi
5468                 # tested with SunOS 4.1.1 and gcc 2.7.0
5469                 if test "$GCC" != yes; then
5470                         CC_SHARED_OPTS='-KPIC'
5471                 fi
5472                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
5473                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5474                 ;;
5475         solaris2*) #(vi
5476                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
5477                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
5478                 if test "$DFT_LWR_MODEL" = "shared" ; then
5479                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
5480                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5481                 fi
5482                 if test "$cf_cv_enable_rpath" = yes ; then
5483                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
5484                 fi
5485                 CF_SHARED_SONAME
5486                 if test "$GCC" != yes; then
5487                         cf_save_CFLAGS="$CFLAGS"
5488                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
5489                         do
5490                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
5491                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
5492                         done
5493                         CFLAGS="$cf_save_CFLAGS"
5494                         CC_SHARED_OPTS=$cf_shared_opts
5495                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5496                 else
5497                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5498                 fi
5499                 ;;
5500         sysv5uw7*|unix_sv*) #(vi
5501                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
5502                 if test "$GCC" != yes; then
5503                         CC_SHARED_OPTS='-KPIC'
5504                 fi
5505                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
5506                 ;;
5507         *)
5508                 CC_SHARED_OPTS='unknown'
5509                 MK_SHARED_LIB='echo unknown'
5510                 ;;
5511         esac
5512
5513         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
5514         case "$cf_cv_shlib_version" in #(vi
5515         rel|abi)
5516                 case "$MK_SHARED_LIB" in #(vi
5517                 *'-o $[@]') #(vi
5518                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
5519                         ;;
5520                 *)
5521                         AC_MSG_WARN(ignored --with-shlib-version)
5522                         ;;
5523                 esac
5524                 ;;
5525         esac
5526
5527         # RPATH_LIST is a colon-separated list of directories
5528         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
5529         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
5530
5531         AC_SUBST(CC_SHARED_OPTS)
5532         AC_SUBST(LD_RPATH_OPT)
5533         AC_SUBST(LD_SHARED_OPTS)
5534         AC_SUBST(MK_SHARED_LIB)
5535         AC_SUBST(LINK_PROGS)
5536         AC_SUBST(LINK_TESTS)
5537         AC_SUBST(EXTRA_LDFLAGS)
5538         AC_SUBST(LOCAL_LDFLAGS)
5539         AC_SUBST(LOCAL_LDFLAGS2)
5540         AC_SUBST(INSTALL_LIB)
5541         AC_SUBST(RPATH_LIST)
5542 ])dnl
5543 dnl ---------------------------------------------------------------------------
5544 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
5545 dnl ----------------
5546 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
5547 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
5548 dnl option.
5549 dnl
5550 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
5551 dnl If missing, use "rel".
5552 define([CF_SHARED_SONAME],
5553 [
5554         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
5555         if test "$cf_cv_shlib_version" = rel; then
5556                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
5557         else
5558                 cf_cv_shared_soname='`basename $[@]`'
5559         fi
5560 ])
5561 dnl ---------------------------------------------------------------------------
5562 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
5563 dnl -----------
5564 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
5565 dnl programs need this test).
5566 dnl
5567 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
5568 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
5569 dnl winsize declaration is left alone - we may revisit this if Apple choose to
5570 dnl break that part of the interface as well.
5571 AC_DEFUN([CF_SIGWINCH],
5572 [
5573 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
5574         AC_TRY_COMPILE([
5575 #include <sys/types.h>
5576 #include <sys/signal.h>
5577 ],[int x = SIGWINCH],
5578         [cf_cv_define_sigwinch=yes],
5579         [AC_TRY_COMPILE([
5580 #undef _XOPEN_SOURCE
5581 #undef _POSIX_SOURCE
5582 #undef _POSIX_C_SOURCE
5583 #include <sys/types.h>
5584 #include <sys/signal.h>
5585 ],[int x = SIGWINCH],
5586         [cf_cv_define_sigwinch=maybe],
5587         [cf_cv_define_sigwinch=no])
5588 ])
5589 ])
5590
5591 if test "$cf_cv_define_sigwinch" = maybe ; then
5592 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
5593 cf_cv_fixup_sigwinch=unknown
5594 cf_sigwinch=32
5595 while test $cf_sigwinch != 1
5596 do
5597         AC_TRY_COMPILE([
5598 #undef _XOPEN_SOURCE
5599 #undef _POSIX_SOURCE
5600 #undef _POSIX_C_SOURCE
5601 #include <sys/types.h>
5602 #include <sys/signal.h>
5603 ],[
5604 #if SIGWINCH != $cf_sigwinch
5605 make an error
5606 #endif
5607 int x = SIGWINCH],
5608         [cf_cv_fixup_sigwinch=$cf_sigwinch
5609          break])
5610
5611 cf_sigwinch=`expr $cf_sigwinch - 1`
5612 done
5613 ])
5614
5615         if test "$cf_cv_fixup_sigwinch" != unknown ; then
5616                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
5617         fi
5618 fi
5619 ])dnl
5620 dnl ---------------------------------------------------------------------------
5621 dnl CF_SIG_ATOMIC_T version: 2 updated: 2005/09/18 17:27:12
5622 dnl ---------------
5623 dnl signal handler, but there are some gcc depedencies in that recommendation.
5624 dnl Try anyway.
5625 AC_DEFUN([CF_SIG_ATOMIC_T],
5626 [
5627 AC_MSG_CHECKING(for signal global datatype)
5628 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
5629         for cf_type in \
5630                 "volatile sig_atomic_t" \
5631                 "sig_atomic_t" \
5632                 "int"
5633         do
5634         AC_TRY_COMPILE([
5635 #include <sys/types.h>
5636 #include <signal.h>
5637 #include <stdio.h>
5638
5639 extern $cf_type x;
5640 $cf_type x;
5641 static void handler(int sig)
5642 {
5643         x = 5;
5644 }],
5645                 [signal(SIGINT, handler);
5646                  x = 1],
5647                 [cf_cv_sig_atomic_t=$cf_type],
5648                 [cf_cv_sig_atomic_t=no])
5649                 test "$cf_cv_sig_atomic_t" != no && break
5650         done
5651         ])
5652 AC_MSG_RESULT($cf_cv_sig_atomic_t)
5653 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t)
5654 ])dnl
5655 dnl ---------------------------------------------------------------------------
5656 dnl CF_SIZECHANGE version: 8 updated: 2000/11/04 12:22:16
5657 dnl -------------
5658 dnl Check for definitions & structures needed for window size-changing
5659 dnl FIXME: check that this works with "snake" (HP-UX 10.x)
5660 AC_DEFUN([CF_SIZECHANGE],
5661 [
5662 AC_REQUIRE([CF_STRUCT_TERMIOS])
5663 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
5664     cf_cv_sizechange=unknown
5665     cf_save_CPPFLAGS="$CPPFLAGS"
5666
5667 for cf_opts in "" "NEED_PTEM_H"
5668 do
5669
5670     CPPFLAGS="$cf_save_CPPFLAGS"
5671     test -n "$cf_opts" && CPPFLAGS="$CPPFLAGS -D$cf_opts"
5672     AC_TRY_COMPILE([#include <sys/types.h>
5673 #ifdef HAVE_TERMIOS_H
5674 #include <termios.h>
5675 #else
5676 #ifdef HAVE_TERMIO_H
5677 #include <termio.h>
5678 #endif
5679 #endif
5680 #ifdef NEED_PTEM_H
5681 /* This is a workaround for SCO:  they neglected to define struct winsize in
5682  * termios.h -- it's only in termio.h and ptem.h
5683  */
5684 #include        <sys/stream.h>
5685 #include        <sys/ptem.h>
5686 #endif
5687 #if !defined(sun) || !defined(HAVE_TERMIOS_H)
5688 #include <sys/ioctl.h>
5689 #endif
5690 ],[
5691 #ifdef TIOCGSIZE
5692         struct ttysize win;     /* FIXME: what system is this? */
5693         int y = win.ts_lines;
5694         int x = win.ts_cols;
5695 #else
5696 #ifdef TIOCGWINSZ
5697         struct winsize win;
5698         int y = win.ws_row;
5699         int x = win.ws_col;
5700 #else
5701         no TIOCGSIZE or TIOCGWINSZ
5702 #endif /* TIOCGWINSZ */
5703 #endif /* TIOCGSIZE */
5704         ],
5705         [cf_cv_sizechange=yes],
5706         [cf_cv_sizechange=no])
5707
5708         CPPFLAGS="$cf_save_CPPFLAGS"
5709         if test "$cf_cv_sizechange" = yes ; then
5710                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
5711                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
5712                 break
5713         fi
5714 done
5715 ])
5716 if test "$cf_cv_sizechange" != no ; then
5717         AC_DEFINE(HAVE_SIZECHANGE)
5718         case $cf_cv_sizechange in #(vi
5719         NEED*)
5720                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
5721                 ;;
5722         esac
5723 fi
5724 ])dnl
5725 dnl ---------------------------------------------------------------------------
5726 dnl CF_SRC_MODULES version: 26 updated: 2012/01/07 15:08:24
5727 dnl --------------
5728 dnl For each parameter, test if the source-directory exists, and if it contains
5729 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
5730 dnl use in CF_LIB_RULES.
5731 dnl
5732 dnl This uses the configured value to make the lists SRC_SUBDIRS and
5733 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
5734 AC_DEFUN([CF_SRC_MODULES],
5735 [
5736 AC_MSG_CHECKING(for src modules)
5737
5738 # dependencies and linker-arguments for test-programs
5739 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
5740 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
5741 if test "$DFT_LWR_MODEL" = "libtool"; then
5742         TEST_ARGS="${TEST_DEPS}"
5743         TEST_ARG2="${TEST_DEP2}"
5744 else
5745         TEST_ARGS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
5746         TEST_ARG2="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARG2"
5747 fi
5748
5749 PC_MODULES_TO_MAKE="ncurses${DFT_ARG_SUFFIX}"
5750 cf_cv_src_modules=
5751 for cf_dir in $1
5752 do
5753         if test -f $srcdir/$cf_dir/modules; then
5754
5755                 # We may/may not have tack in the distribution, though the
5756                 # makefile is.
5757                 if test $cf_dir = tack ; then
5758                         if test ! -f $srcdir/${cf_dir}/${cf_dir}.h; then
5759                                 continue
5760                         fi
5761                 fi
5762
5763                 if test -z "$cf_cv_src_modules"; then
5764                         cf_cv_src_modules=$cf_dir
5765                 else
5766                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
5767                 fi
5768
5769                 # Make the ncurses_cfg.h file record the library interface files as
5770                 # well.  These are header files that are the same name as their
5771                 # directory.  Ncurses is the only library that does not follow
5772                 # that pattern.
5773                 if test $cf_dir = tack ; then
5774                         continue
5775                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
5776                         CF_UPPER(cf_have_include,$cf_dir)
5777                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
5778                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
5779                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
5780                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
5781                         if test "$DFT_LWR_MODEL" = "libtool"; then
5782                                 TEST_ARGS="${TEST_DEPS}"
5783                                 TEST_ARG2="${TEST_DEP2}"
5784                         else
5785                                 TEST_ARGS="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARGS"
5786                                 TEST_ARG2="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARG2"
5787                         fi
5788                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${DFT_ARG_SUFFIX}"
5789                 fi
5790         fi
5791 done
5792 AC_MSG_RESULT($cf_cv_src_modules)
5793
5794 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
5795 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
5796
5797 AC_SUBST(TEST_ARGS)
5798 AC_SUBST(TEST_DEPS)
5799
5800 AC_SUBST(TEST_ARG2)
5801 AC_SUBST(TEST_DEP2)
5802
5803 SRC_SUBDIRS=
5804 if test "x$cf_with_manpages" != xno ; then
5805         SRC_SUBDIRS="$SRC_SUBDIRS man"
5806 fi
5807 SRC_SUBDIRS="$SRC_SUBDIRS include"
5808 for cf_dir in $cf_cv_src_modules
5809 do
5810         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
5811 done
5812 if test "x$cf_with_tests" != "xno" ; then
5813         SRC_SUBDIRS="$SRC_SUBDIRS test"
5814 fi
5815 test -z "$MAKE_TERMINFO" && SRC_SUBDIRS="$SRC_SUBDIRS misc"
5816 if test "$cf_with_cxx_binding" != no; then
5817         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${DFT_ARG_SUFFIX}"
5818         SRC_SUBDIRS="$SRC_SUBDIRS c++"
5819 fi
5820
5821 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
5822 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
5823
5824 AC_SUBST(PC_MODULES_TO_MAKE)
5825
5826 ADA_SUBDIRS=
5827 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
5828         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
5829         ADA_SUBDIRS="gen src"
5830         if test "x$cf_with_tests" != "xno" ; then
5831                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
5832         fi
5833 fi
5834
5835 SUB_MAKEFILES=
5836 for cf_dir in $SRC_SUBDIRS
5837 do
5838         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
5839 done
5840
5841 if test -n "$ADA_SUBDIRS"; then
5842         for cf_dir in $ADA_SUBDIRS
5843         do
5844                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
5845         done
5846         AC_SUBST(ADA_SUBDIRS)
5847 fi
5848 ])dnl
5849 dnl ---------------------------------------------------------------------------
5850 dnl CF_STDCPP_LIBRARY version: 7 updated: 2010/05/29 16:31:02
5851 dnl -----------------
5852 dnl Check for -lstdc++, which is GNU's standard C++ library.
5853 AC_DEFUN([CF_STDCPP_LIBRARY],
5854 [
5855 if test -n "$GXX" ; then
5856 case $cf_cv_system_name in #(vi
5857 os2*) #(vi
5858         cf_stdcpp_libname=stdcpp
5859         ;;
5860 *)
5861         cf_stdcpp_libname=stdc++
5862         ;;
5863 esac
5864 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
5865         cf_save="$LIBS"
5866         CF_ADD_LIB($cf_stdcpp_libname)
5867 AC_TRY_LINK([
5868 #include <strstream.h>],[
5869 char buf[80];
5870 strstreambuf foo(buf, sizeof(buf))
5871 ],
5872         [cf_cv_libstdcpp=yes],
5873         [cf_cv_libstdcpp=no])
5874         LIBS="$cf_save"
5875 ])
5876 test "$cf_cv_libstdcpp" = yes && CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS)
5877 fi
5878 ])dnl
5879 dnl ---------------------------------------------------------------------------
5880 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
5881 dnl --------------
5882 dnl     Remove "-g" option from the compiler options
5883 AC_DEFUN([CF_STRIP_G_OPT],
5884 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
5885 dnl ---------------------------------------------------------------------------
5886 dnl CF_STRUCT_SIGACTION version: 4 updated: 2011/04/16 11:52:53
5887 dnl -------------------
5888 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
5889 dnl do this if we've found the sigaction function.
5890 AC_DEFUN([CF_STRUCT_SIGACTION],[
5891 AC_REQUIRE([CF_XOPEN_SOURCE])
5892
5893 if test "$ac_cv_func_sigaction" = yes; then
5894 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
5895 AC_TRY_COMPILE([
5896 #include <sys/types.h>
5897 #include <signal.h>],
5898         [struct sigaction act],
5899         [sigact_bad=no],
5900         [
5901 AC_TRY_COMPILE([
5902 #define _POSIX_SOURCE
5903 #include <sys/types.h>
5904 #include <signal.h>],
5905         [struct sigaction act],
5906         [sigact_bad=yes
5907          AC_DEFINE(_POSIX_SOURCE)],
5908          [sigact_bad=unknown])])
5909 AC_MSG_RESULT($sigact_bad)
5910 fi
5911 ])dnl
5912 dnl ---------------------------------------------------------------------------
5913 dnl CF_STRUCT_TERMIOS version: 6 updated: 2011/04/16 11:52:53
5914 dnl -----------------
5915 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
5916 AC_DEFUN([CF_STRUCT_TERMIOS],[
5917 AC_REQUIRE([CF_XOPEN_SOURCE])
5918
5919 AC_CHECK_HEADERS( \
5920 termio.h \
5921 termios.h \
5922 unistd.h \
5923 )
5924
5925 if test "$ISC" = yes ; then
5926         AC_CHECK_HEADERS( sys/termio.h )
5927 fi
5928 if test "$ac_cv_header_termios_h" = yes ; then
5929         case "$CFLAGS $CPPFLAGS" in
5930         *-D_POSIX_SOURCE*)
5931                 termios_bad=dunno ;;
5932         *)      termios_bad=maybe ;;
5933         esac
5934         if test "$termios_bad" = maybe ; then
5935         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
5936         AC_TRY_COMPILE([#include <termios.h>],
5937                 [struct termios foo; int x = foo.c_iflag],
5938                 termios_bad=no, [
5939                 AC_TRY_COMPILE([
5940 #define _POSIX_SOURCE
5941 #include <termios.h>],
5942                         [struct termios foo; int x = foo.c_iflag],
5943                         termios_bad=unknown,
5944                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE))
5945                         ])
5946         AC_MSG_RESULT($termios_bad)
5947         fi
5948 fi
5949 ])dnl
5950 dnl ---------------------------------------------------------------------------
5951 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
5952 dnl --------------
5953 dnl Construct a search-list for a nonstandard header/lib-file
5954 dnl     $1 = the variable to return as result
5955 dnl     $2 = the package name
5956 dnl     $3 = the subdirectory, e.g., bin, include or lib
5957 AC_DEFUN([CF_SUBDIR_PATH],
5958 [
5959 $1=
5960
5961 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
5962 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
5963 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
5964 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
5965 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
5966 ])dnl
5967 dnl ---------------------------------------------------------------------------
5968 dnl CF_SUBST version: 4 updated: 2006/06/17 12:33:03
5969 dnl --------
5970 dnl     Shorthand macro for substituting things that the user may override
5971 dnl     with an environment variable.
5972 dnl
5973 dnl     $1 = long/descriptive name
5974 dnl     $2 = environment variable
5975 dnl     $3 = default value
5976 AC_DEFUN([CF_SUBST],
5977 [AC_CACHE_VAL(cf_cv_subst_$2,[
5978 AC_MSG_CHECKING(for $1 (symbol $2))
5979 CF_SUBST_IF([-z "[$]$2"], [$2], [$3])
5980 cf_cv_subst_$2=[$]$2
5981 AC_MSG_RESULT([$]$2)
5982 ])
5983 ])dnl
5984 dnl ---------------------------------------------------------------------------
5985 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
5986 dnl -----------
5987 dnl     Shorthand macro for substituting things that the user may override
5988 dnl     with an environment variable.
5989 dnl
5990 dnl     $1 = condition to pass to "test"
5991 dnl     $2 = environment variable
5992 dnl     $3 = value if the test succeeds
5993 dnl     $4 = value if the test fails
5994 AC_DEFUN([CF_SUBST_IF],
5995 [
5996 if test $1 ; then
5997         $2=$3
5998 ifelse($4,,,[else
5999         $2=$4])
6000 fi
6001 AC_SUBST($2)
6002 ])dnl
6003 dnl ---------------------------------------------------------------------------
6004 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
6005 dnl ------------------------
6006 dnl Get the version-number for use in shared-library naming, etc.
6007 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
6008 [
6009 AC_REQUIRE([CF_PROG_EGREP])
6010 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6011 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6012 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6013 cf_cv_abi_version=${NCURSES_MAJOR}
6014 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
6015 dnl Show the computed version, for logging
6016 cf_cv_timestamp=`date`
6017 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
6018 dnl We need these values in the generated headers
6019 AC_SUBST(NCURSES_MAJOR)
6020 AC_SUBST(NCURSES_MINOR)
6021 AC_SUBST(NCURSES_PATCH)
6022 dnl We need these values in the generated makefiles
6023 AC_SUBST(cf_cv_rel_version)
6024 AC_SUBST(cf_cv_abi_version)
6025 AC_SUBST(cf_cv_builtin_bool)
6026 AC_SUBST(cf_cv_header_stdbool_h)
6027 AC_SUBST(cf_cv_type_of_bool)dnl
6028 ])dnl
6029 dnl ---------------------------------------------------------------------------
6030 dnl CF_SYS_TIME_SELECT version: 4 updated: 2000/10/04 09:18:40
6031 dnl ------------------
6032 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
6033 dnl older SCO configurations.
6034 AC_DEFUN([CF_SYS_TIME_SELECT],
6035 [
6036 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
6037 AC_CACHE_VAL(cf_cv_sys_time_select,[
6038 AC_TRY_COMPILE([
6039 #include <sys/types.h>
6040 #ifdef HAVE_SYS_TIME_H
6041 #include <sys/time.h>
6042 #endif
6043 #ifdef HAVE_SYS_SELECT_H
6044 #include <sys/select.h>
6045 #endif
6046 ],[],[cf_cv_sys_time_select=yes],
6047      [cf_cv_sys_time_select=no])
6048      ])
6049 AC_MSG_RESULT($cf_cv_sys_time_select)
6050 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT)
6051 ])dnl
6052 dnl ---------------------------------------------------------------------------
6053 dnl CF_TOP_BUILDDIR version: 1 updated: 2006/10/15 16:33:23
6054 dnl ---------------
6055 dnl Define a top_builddir symbol, for applications that need an absolute path.
6056 AC_DEFUN([CF_TOP_BUILDDIR],
6057 [
6058 top_builddir=`pwd`
6059 AC_SUBST(top_builddir)
6060 ])dnl
6061 dnl ---------------------------------------------------------------------------
6062 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
6063 dnl -------------------
6064 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
6065 dnl can define it successfully.
6066 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
6067 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
6068         AC_TRY_COMPILE([
6069 #include <stdlib.h>
6070 #include <string.h>
6071 #include <sys/types.h>
6072 ],[
6073 #ifndef _XOPEN_SOURCE
6074 make an error
6075 #endif],
6076         [cf_cv_xopen_source=no],
6077         [cf_save="$CPPFLAGS"
6078          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6079          AC_TRY_COMPILE([
6080 #include <stdlib.h>
6081 #include <string.h>
6082 #include <sys/types.h>
6083 ],[
6084 #ifdef _XOPEN_SOURCE
6085 make an error
6086 #endif],
6087         [cf_cv_xopen_source=no],
6088         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
6089         CPPFLAGS="$cf_save"
6090         ])
6091 ])
6092
6093 if test "$cf_cv_xopen_source" != no ; then
6094         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
6095         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
6096         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
6097         CF_ADD_CFLAGS($cf_temp_xopen_source)
6098 fi
6099 ])
6100 dnl ---------------------------------------------------------------------------
6101 dnl CF_TYPEOF_CHTYPE version: 8 updated: 2006/12/16 12:33:30
6102 dnl ----------------
6103 dnl Determine the type we should use for chtype (and attr_t, which is treated
6104 dnl as the same thing).  We want around 32 bits, so on most machines want a
6105 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
6106 dnl wide characters, we have to have a type compatible with that, as well.
6107 AC_DEFUN([CF_TYPEOF_CHTYPE],
6108 [
6109 AC_MSG_CHECKING([for type of chtype])
6110 AC_CACHE_VAL(cf_cv_typeof_chtype,[
6111                 AC_TRY_RUN([
6112 #define WANT_BITS 31
6113 #include <stdio.h>
6114 int main()
6115 {
6116         FILE *fp = fopen("cf_test.out", "w");
6117         if (fp != 0) {
6118                 char *result = "long";
6119                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
6120                         int n;
6121                         unsigned int x, y;
6122                         for (n = 0; n < WANT_BITS; n++) {
6123                                 x = (1 << n);
6124                                 y = (x >> n);
6125                                 if (y != 1 || x == 0) {
6126                                         x = 0;
6127                                         break;
6128                                 }
6129                         }
6130                         /*
6131                          * If x is nonzero, an int is big enough for the bits
6132                          * that we want.
6133                          */
6134                         result = (x != 0) ? "int" : "long";
6135                 }
6136                 fputs(result, fp);
6137                 fclose(fp);
6138         }
6139         ${cf_cv_main_return:-return}(0);
6140 }
6141                 ],
6142                 [cf_cv_typeof_chtype=`cat cf_test.out`],
6143                 [cf_cv_typeof_chtype=long],
6144                 [cf_cv_typeof_chtype=long])
6145                 rm -f cf_test.out
6146         ])
6147 AC_MSG_RESULT($cf_cv_typeof_chtype)
6148
6149 AC_SUBST(cf_cv_typeof_chtype)
6150 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype)
6151 ])dnl
6152 dnl ---------------------------------------------------------------------------
6153 dnl CF_TYPE_SIGACTION version: 3 updated: 2000/08/12 23:18:52
6154 dnl -----------------
6155 dnl
6156 AC_DEFUN([CF_TYPE_SIGACTION],
6157 [
6158 AC_MSG_CHECKING([for type sigaction_t])
6159 AC_CACHE_VAL(cf_cv_type_sigaction,[
6160         AC_TRY_COMPILE([
6161 #include <signal.h>],
6162                 [sigaction_t x],
6163                 [cf_cv_type_sigaction=yes],
6164                 [cf_cv_type_sigaction=no])])
6165 AC_MSG_RESULT($cf_cv_type_sigaction)
6166 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION)
6167 ])dnl
6168 dnl ---------------------------------------------------------------------------
6169 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
6170 dnl --------------------
6171 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
6172 dnl won't, but they're still there.
6173 AC_DEFUN([CF_UNSIGNED_LITERALS],
6174 [
6175 AC_MSG_CHECKING([if unsigned literals are legal])
6176 AC_CACHE_VAL(cf_cv_unsigned_literals,[
6177         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
6178                 [cf_cv_unsigned_literals=yes],
6179                 [cf_cv_unsigned_literals=no])
6180         ])
6181 AC_MSG_RESULT($cf_cv_unsigned_literals)
6182 ])dnl
6183 dnl ---------------------------------------------------------------------------
6184 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
6185 dnl --------
6186 dnl Make an uppercase version of a variable
6187 dnl $1=uppercase($2)
6188 AC_DEFUN([CF_UPPER],
6189 [
6190 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6191 ])dnl
6192 dnl ---------------------------------------------------------------------------
6193 dnl CF_UTF8_LIB version: 7 updated: 2010/06/20 09:24:28
6194 dnl -----------
6195 dnl Check for multibyte support, and if not found, utf8 compatibility library
6196 AC_DEFUN([CF_UTF8_LIB],
6197 [
6198 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
6199         cf_save_LIBS="$LIBS"
6200         AC_TRY_LINK([
6201 #include <stdlib.h>],[putwc(0,0);],
6202         [cf_cv_utf8_lib=yes],
6203         [CF_FIND_LINKAGE([
6204 #include <libutf8.h>],[putwc(0,0);],utf8,
6205                 [cf_cv_utf8_lib=add-on],
6206                 [cf_cv_utf8_lib=no])
6207 ])])
6208
6209 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
6210 # ncurses/ncursesw:
6211 if test "$cf_cv_utf8_lib" = "add-on" ; then
6212         AC_DEFINE(HAVE_LIBUTF8_H)
6213         CF_ADD_INCDIR($cf_cv_header_path_utf8)
6214         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
6215         CF_ADD_LIBS($cf_cv_library_file_utf8)
6216 fi
6217 ])dnl
6218 dnl ---------------------------------------------------------------------------
6219 dnl CF_VA_COPY version: 2 updated: 2010/03/04 05:37:29
6220 dnl ----------
6221 dnl check for va_copy, part of stdarg.h
6222 dnl Also, workaround for glibc's __va_copy, by checking for both.
6223 AC_DEFUN([CF_VA_COPY],[
6224 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
6225 AC_TRY_LINK([
6226 #include <stdarg.h>
6227 ],[
6228         static va_list dst;
6229         static va_list src;
6230         va_copy(dst, src)],
6231         cf_cv_have_va_copy=yes,
6232         cf_cv_have_va_copy=no)])
6233
6234 test "$cf_cv_have_va_copy" = yes && AC_DEFINE(HAVE_VA_COPY)
6235
6236 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
6237 AC_TRY_LINK([
6238 #include <stdarg.h>
6239 ],[
6240         static va_list dst;
6241         static va_list src;
6242         __va_copy(dst, src)],
6243         cf_cv_have___va_copy=yes,
6244         cf_cv_have___va_copy=no)])
6245
6246 test "$cf_cv_have___va_copy" = yes && AC_DEFINE(HAVE___VA_COPY)
6247 ])
6248 dnl ---------------------------------------------------------------------------
6249 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
6250 dnl ----------
6251 dnl Use AC_VERBOSE w/o the warnings
6252 AC_DEFUN([CF_VERBOSE],
6253 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
6254 CF_MSG_LOG([$1])
6255 ])dnl
6256 dnl ---------------------------------------------------------------------------
6257 dnl CF_WCHAR_TYPE version: 3 updated: 2010/05/26 16:44:57
6258 dnl -------------
6259 dnl Check if type wide-character type $1 is declared, and if so, which header
6260 dnl file is needed.  The second parameter is used to set a shell variable when
6261 dnl the type is not found.  The first parameter sets a shell variable for the
6262 dnl opposite sense.
6263 AC_DEFUN([CF_WCHAR_TYPE],
6264 [
6265 # This is needed on Tru64 5.0 to declare $1
6266 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
6267 AC_TRY_COMPILE([
6268 #include <stdlib.h>
6269 #include <stdarg.h>
6270 #include <stdio.h>
6271 #ifdef HAVE_LIBUTF8_H
6272 #include <libutf8.h>
6273 #endif],
6274         [$1 state],
6275         [cf_cv_$1=no],
6276         [AC_TRY_COMPILE([
6277 #include <stdlib.h>
6278 #include <stdarg.h>
6279 #include <stdio.h>
6280 #include <wchar.h>
6281 #ifdef HAVE_LIBUTF8_H
6282 #include <libutf8.h>
6283 #endif],
6284         [$1 value],
6285         [cf_cv_$1=yes],
6286         [cf_cv_$1=unknown])])])
6287
6288 if test "$cf_cv_$1" = yes ; then
6289         AC_DEFINE(NEED_WCHAR_H)
6290         NEED_WCHAR_H=1
6291 fi
6292
6293 ifelse([$2],,,[
6294 # if we do not find $1 in either place, use substitution to provide a fallback.
6295 if test "$cf_cv_$1" = unknown ; then
6296         $2=1
6297 fi
6298 ])
6299 ifelse($3,,,[
6300 # if we find $1 in either place, use substitution to provide a fallback.
6301 if test "$cf_cv_$1" != unknown ; then
6302         $3=1
6303 fi
6304 ])
6305 ])dnl
6306 dnl ---------------------------------------------------------------------------
6307 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
6308 dnl ---------------
6309 dnl Check for compiler-support for weak symbols.
6310 dnl This works with "recent" gcc.
6311 AC_DEFUN([CF_WEAK_SYMBOLS],[
6312 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
6313
6314 AC_TRY_COMPILE([
6315 #include <stdio.h>],
6316 [
6317 #if defined(__GNUC__)
6318 #  if defined __USE_ISOC99
6319 #    define _cat_pragma(exp)    _Pragma(#exp)
6320 #    define _weak_pragma(exp)   _cat_pragma(weak name)
6321 #  else
6322 #    define _weak_pragma(exp)
6323 #  endif
6324 #  define _declare(name)        __extension__ extern __typeof__(name) name
6325 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
6326 #endif
6327
6328 weak_symbol(fopen);
6329 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
6330 ])
6331 ])dnl
6332 dnl ---------------------------------------------------------------------------
6333 dnl CF_WITH_ABI_VERSION version: 1 updated: 2003/09/20 18:12:49
6334 dnl -------------------
6335 dnl Allow library's ABI to be overridden.  Generally this happens when a
6336 dnl packager has incremented the ABI past that used in the original package,
6337 dnl and wishes to keep doing this.
6338 dnl
6339 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
6340 dnl symbol.
6341 AC_DEFUN([CF_WITH_ABI_VERSION],[
6342 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
6343 AC_ARG_WITH(abi-version,
6344 [  --with-abi-version=XXX  override derived ABI version],
6345 [AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
6346  cf_cv_abi_version=$withval])
6347  CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
6348 ifelse($1,,,[
6349 $1_ABI=$cf_cv_abi_version
6350 ])
6351 ])dnl
6352 dnl ---------------------------------------------------------------------------
6353 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
6354 dnl --------------------
6355 dnl Command-line option to specify the Ada95 compiler.
6356 AC_DEFUN([CF_WITH_ADA_COMPILER],[
6357 AC_MSG_CHECKING(for ada-compiler)
6358 AC_ARG_WITH(ada-compiler,
6359         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
6360         [cf_ada_compiler=$withval],
6361         [cf_ada_compiler=gnatmake])
6362 AC_SUBST(cf_ada_compiler)
6363 AC_MSG_RESULT($cf_ada_compiler)
6364 ])dnl
6365 dnl ---------------------------------------------------------------------------
6366 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
6367 dnl -------------------
6368 dnl Command-line option to specify where Ada includes will install.
6369 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
6370 AC_MSG_CHECKING(for ada-include)
6371 CF_WITH_PATH(ada-include,
6372    [  --with-ada-include=DIR  Ada includes are in DIR],
6373    ADA_INCLUDE,
6374    PREFIX/share/ada/adainclude,
6375    [$]prefix/share/ada/adainclude)
6376 AC_SUBST(ADA_INCLUDE)
6377 AC_MSG_RESULT($ADA_INCLUDE)
6378 ])dnl
6379 dnl ---------------------------------------------------------------------------
6380 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
6381 dnl -------------------
6382 dnl Command-line option to specify where Ada objects will install.
6383 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
6384 AC_MSG_CHECKING(for ada-objects)
6385 CF_WITH_PATH(ada-objects,
6386    [  --with-ada-objects=DIR  Ada objects are in DIR],
6387    ADA_OBJECTS,
6388    PREFIX/lib/ada/adalib,
6389    [$]prefix/lib/ada/adalib)
6390 AC_SUBST(ADA_OBJECTS)
6391 AC_MSG_RESULT($ADA_OBJECTS)
6392 ])dnl
6393 dnl ---------------------------------------------------------------------------
6394 dnl CF_WITH_ADA_SHAREDLIB version: 2 updated: 2010/06/26 17:35:58
6395 dnl ---------------------
6396 dnl Command-line option to specify if an Ada95 shared-library should be built,
6397 dnl and optionally what its soname should be.
6398 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
6399 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
6400 AC_ARG_WITH(ada-sharedlib,
6401         [  --with-ada-sharedlib=XX build Ada95 shared-library],
6402         [with_ada_sharedlib=$withval],
6403         [with_ada_sharedlib=no])
6404 AC_MSG_RESULT($with_ada_sharedlib)
6405
6406 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
6407 MAKE_ADA_SHAREDLIB="#"
6408
6409 if test "x$with_ada_sharedlib" != xno
6410 then
6411         MAKE_ADA_SHAREDLIB=
6412         if test "x$with_ada_sharedlib" != xyes
6413         then
6414                 ADA_SHAREDLIB="$with_ada_sharedlib"
6415         fi
6416 fi
6417
6418 AC_SUBST(ADA_SHAREDLIB)
6419 AC_SUBST(MAKE_ADA_SHAREDLIB)
6420 ])dnl
6421 dnl ---------------------------------------------------------------------------
6422 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
6423 dnl ----------------
6424 dnl Configure-option for dbmalloc.  The optional parameter is used to override
6425 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6426 AC_DEFUN([CF_WITH_DBMALLOC],[
6427 CF_NO_LEAKS_OPTION(dbmalloc,
6428         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
6429         [USE_DBMALLOC])
6430
6431 if test "$with_dbmalloc" = yes ; then
6432         AC_CHECK_HEADER(dbmalloc.h,
6433                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
6434 fi
6435 ])dnl
6436 dnl ---------------------------------------------------------------------------
6437 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
6438 dnl ---------------
6439 dnl Configure-option for dmalloc.  The optional parameter is used to override
6440 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6441 AC_DEFUN([CF_WITH_DMALLOC],[
6442 CF_NO_LEAKS_OPTION(dmalloc,
6443         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
6444         [USE_DMALLOC])
6445
6446 if test "$with_dmalloc" = yes ; then
6447         AC_CHECK_HEADER(dmalloc.h,
6448                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
6449 fi
6450 ])dnl
6451 dnl ---------------------------------------------------------------------------
6452 dnl CF_WITH_GPM version: 7 updated: 2008/03/23 14:48:54
6453 dnl -----------
6454 dnl
6455 dnl The option parameter (if neither yes/no) is assumed to be the name of
6456 dnl the gpm library, e.g., for dynamic loading.
6457 AC_DEFUN([CF_WITH_GPM],
6458 [
6459 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
6460 AC_ARG_WITH(gpm,
6461         [  --with-gpm              use Alessandro Rubini's GPM library],
6462         [with_gpm=$withval],
6463         [with_gpm=maybe])
6464 AC_MSG_RESULT($with_gpm)
6465
6466 if test "$with_gpm" != no ; then
6467         AC_CHECK_HEADER(gpm.h,[
6468                 AC_DEFINE(HAVE_GPM_H)
6469                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
6470                         CF_VERBOSE(assuming we really have GPM library)
6471                         AC_DEFINE(HAVE_LIBGPM)
6472                 else
6473                         AC_CHECK_LIB(gpm,Gpm_Open,[:],[
6474                                 AC_MSG_ERROR(Cannot link with GPM library)
6475                 fi
6476                 with_gpm=yes
6477                 ])
6478         ],[
6479                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
6480                 with_gpm=no
6481         ])
6482 fi
6483 ])
6484 dnl ---------------------------------------------------------------------------
6485 dnl CF_WITH_LIBTOOL version: 28 updated: 2011/07/02 15:40:32
6486 dnl ---------------
6487 dnl Provide a configure option to incorporate libtool.  Define several useful
6488 dnl symbols for the makefile rules.
6489 dnl
6490 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
6491 dnl macros from libtool.m4 which is in the aclocal directory of automake.
6492 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
6493 dnl But that still does not work properly since the macro is expanded outside
6494 dnl the CF_WITH_LIBTOOL macro:
6495 dnl
6496 dnl     #!/bin/sh
6497 dnl     ACLOCAL=`aclocal --print-ac-dir`
6498 dnl     if test -z "$ACLOCAL" ; then
6499 dnl             echo cannot find aclocal directory
6500 dnl             exit 1
6501 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
6502 dnl             echo cannot find libtool.m4 file
6503 dnl             exit 1
6504 dnl     fi
6505 dnl
6506 dnl     LOCAL=aclocal.m4
6507 dnl     ORIG=aclocal.m4.orig
6508 dnl
6509 dnl     trap "mv $ORIG $LOCAL" 0 1 2 5 15
6510 dnl     rm -f $ORIG
6511 dnl     mv $LOCAL $ORIG
6512 dnl
6513 dnl     # sed the LIBTOOL= assignment to omit the current directory?
6514 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
6515 dnl     cat $ORIG >>$LOCAL
6516 dnl
6517 dnl     autoconf-257 $*
6518 dnl
6519 AC_DEFUN([CF_WITH_LIBTOOL],
6520 [
6521 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
6522 ifdef([AC_PROG_LIBTOOL],,[
6523 LIBTOOL=
6524 ])
6525 # common library maintenance symbols that are convenient for libtool scripts:
6526 LIB_CREATE='${AR} -cr'
6527 LIB_OBJECT='${OBJECTS}'
6528 LIB_SUFFIX=.a
6529 LIB_PREP="$RANLIB"
6530
6531 # symbols used to prop libtool up to enable it to determine what it should be
6532 # doing:
6533 LIB_CLEAN=
6534 LIB_COMPILE=
6535 LIB_LINK='${CC}'
6536 LIB_INSTALL=
6537 LIB_UNINSTALL=
6538
6539 AC_MSG_CHECKING(if you want to build libraries with libtool)
6540 AC_ARG_WITH(libtool,
6541         [  --with-libtool          generate libraries with libtool],
6542         [with_libtool=$withval],
6543         [with_libtool=no])
6544 AC_MSG_RESULT($with_libtool)
6545 if test "$with_libtool" != "no"; then
6546 ifdef([AC_PROG_LIBTOOL],[
6547         # missing_content_AC_PROG_LIBTOOL{{
6548         AC_PROG_LIBTOOL
6549         # missing_content_AC_PROG_LIBTOOL}}
6550 ],[
6551         if test "$with_libtool" != "yes" ; then
6552                 CF_PATH_SYNTAX(with_libtool)
6553                 LIBTOOL=$with_libtool
6554         else
6555                 AC_PATH_PROG(LIBTOOL,libtool)
6556         fi
6557         if test -z "$LIBTOOL" ; then
6558                 AC_MSG_ERROR(Cannot find libtool)
6559         fi
6560 ])dnl
6561         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${DESTDIR}${libdir} ${LIBTOOL_VERSION} `cut -f1 ${srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
6562         LIB_OBJECT='${OBJECTS:.o=.lo}'
6563         LIB_SUFFIX=.la
6564         LIB_CLEAN='${LIBTOOL} --mode=clean'
6565         LIB_COMPILE='${LIBTOOL} --mode=compile'
6566         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
6567         LIB_INSTALL='${LIBTOOL} --mode=install'
6568         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
6569         LIB_PREP=:
6570
6571         # Show the version of libtool
6572         AC_MSG_CHECKING(version of libtool)
6573
6574         # Save the version in a cache variable - this is not entirely a good
6575         # thing, but the version string from libtool is very ugly, and for
6576         # bug reports it might be useful to have the original string. "("
6577         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
6578         AC_MSG_RESULT($cf_cv_libtool_version)
6579         if test -z "$cf_cv_libtool_version" ; then
6580                 AC_MSG_ERROR(This is not GNU libtool)
6581         fi
6582
6583         # special hack to add -no-undefined (which libtool should do for itself)
6584         LT_UNDEF=
6585         case "$cf_cv_system_name" in #(vi
6586         cygwin*|mingw32*|uwin*|aix[[4-7]]) #(vi
6587                 LT_UNDEF=-no-undefined
6588                 ;;
6589         esac
6590         AC_SUBST([LT_UNDEF])
6591
6592         # special hack to add --tag option for C++ compiler
6593         case $cf_cv_libtool_version in #(vi
6594         1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*) #(vi
6595                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
6596                 LIBTOOL="$LIBTOOL --tag=CC"
6597                 ;;
6598         *)
6599                 LIBTOOL_CXX="$LIBTOOL"
6600                 ;;
6601         esac
6602 else
6603         LIBTOOL=""
6604         LIBTOOL_CXX=""
6605 fi
6606
6607 test -z "$LIBTOOL" && ECHO_LT=
6608
6609 AC_SUBST(LIBTOOL)
6610 AC_SUBST(LIBTOOL_CXX)
6611 AC_SUBST(LIBTOOL_OPTS)
6612
6613 AC_SUBST(LIB_CREATE)
6614 AC_SUBST(LIB_OBJECT)
6615 AC_SUBST(LIB_SUFFIX)
6616 AC_SUBST(LIB_PREP)
6617
6618 AC_SUBST(LIB_CLEAN)
6619 AC_SUBST(LIB_COMPILE)
6620 AC_SUBST(LIB_LINK)
6621 AC_SUBST(LIB_INSTALL)
6622 AC_SUBST(LIB_UNINSTALL)
6623
6624 ])dnl
6625 dnl ---------------------------------------------------------------------------
6626 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
6627 dnl ------------------
6628 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
6629 dnl "lib" prefix, e.g., because it used the dll naming convention.
6630 dnl
6631 dnl $1 = variable to set
6632 AC_DEFUN([CF_WITH_LIB_PREFIX],
6633 [
6634 AC_MSG_CHECKING(if you want to have a library-prefix)
6635 AC_ARG_WITH(lib-prefix,
6636         [  --with-lib-prefix       override library-prefix],
6637         [with_lib_prefix=$withval],
6638         [with_lib_prefix=auto])
6639 AC_MSG_RESULT($with_lib_prefix)
6640
6641 if test $with_lib_prefix = auto
6642 then
6643         CF_LIB_PREFIX($1)
6644 elif test $with_lib_prefix = no
6645 then
6646         LIB_PREFIX=
6647 else
6648         LIB_PREFIX=$with_lib_prefix
6649 fi
6650 ])dnl
6651 dnl ---------------------------------------------------------------------------
6652 dnl CF_WITH_PATH version: 10 updated: 2010/10/23 15:44:18
6653 dnl ------------
6654 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
6655 dnl defaulting to yes/no.
6656 dnl
6657 dnl $1 = option name
6658 dnl $2 = help-text
6659 dnl $3 = environment variable to set
6660 dnl $4 = default value, shown in the help-message, must be a constant
6661 dnl $5 = default value, if it's an expression & cannot be in the help-message
6662 dnl
6663 AC_DEFUN([CF_WITH_PATH],
6664 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
6665 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
6666 if ifelse([$5],,true,[test -n "$5"]) ; then
6667 CF_PATH_SYNTAX(withval)
6668 fi
6669 $3="$withval"
6670 AC_SUBST($3)dnl
6671 ])dnl
6672 dnl ---------------------------------------------------------------------------
6673 dnl CF_WITH_PATHLIST version: 7 updated: 2010/10/23 16:10:30
6674 dnl ----------------
6675 dnl Process an option specifying a list of colon-separated paths.
6676 dnl
6677 dnl $1 = option name
6678 dnl $2 = help-text
6679 dnl $3 = environment variable to set
6680 dnl $4 = default value, shown in the help-message, must be a constant
6681 dnl $5 = default value, if it's an expression & cannot be in the help-message
6682 dnl $6 = flag to tell if we want to define or substitute
6683 dnl
6684 AC_DEFUN([CF_WITH_PATHLIST],[
6685 AC_REQUIRE([CF_PATHSEP])
6686 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
6687 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
6688
6689 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
6690 cf_dst_path=
6691 for cf_src_path in $withval
6692 do
6693   CF_PATH_SYNTAX(cf_src_path)
6694   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}:"
6695   cf_dst_path="${cf_dst_path}${cf_src_path}"
6696 done
6697 IFS="$ac_save_ifs"
6698
6699 ifelse($6,define,[
6700 # Strip single quotes from the value, e.g., when it was supplied as a literal
6701 # for $4 or $5.
6702 case $cf_dst_path in #(vi
6703 \'*)
6704   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
6705   ;;
6706 esac
6707 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
6708 ])
6709
6710 eval '$3="$cf_dst_path"'
6711 AC_SUBST($3)dnl
6712
6713 ])dnl
6714 dnl ---------------------------------------------------------------------------
6715 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 2 updated: 2011/12/10 18:58:47
6716 dnl -------------------------
6717 dnl Allow the choice of the pkg-config library directory to be overridden.
6718 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
6719 if test "$PKG_CONFIG" != none ; then
6720         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
6721         AC_ARG_WITH(pkg-config-libdir,
6722                 [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
6723                 [PKG_CONFIG_LIBDIR=$withval],
6724                 [PKG_CONFIG_LIBDIR=yes])
6725
6726         case x$PKG_CONFIG_LIBDIR in #(vi
6727         x/*) #(vi
6728                 ;;
6729         xyes) #(vi
6730                 # look for the library directory using the same prefix as the executable
6731                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
6732                 case x`(arch) 2>/dev/null` in #(vi
6733                 *64) #(vi
6734                         for cf_config in $cf_path/share $cf_path/lib64 $cf_path/lib32 $cf_path/lib
6735                         do
6736                                 if test -d $cf_config/pkgconfig
6737                                 then
6738                                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
6739                                         break
6740                                 fi
6741                         done
6742                         ;;
6743                 *)
6744                         PKG_CONFIG_LIBDIR=$cf_path/lib/pkgconfig
6745                         ;;
6746                 esac
6747                 ;;
6748         *)
6749                 ;;
6750         esac
6751
6752         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
6753 fi
6754
6755 AC_SUBST(PKG_CONFIG_LIBDIR)
6756 ])dnl
6757 dnl ---------------------------------------------------------------------------
6758 dnl CF_WITH_PTHREAD version: 5 updated: 2011/12/10 19:01:56
6759 dnl ---------------
6760 dnl Check for POSIX thread library.
6761 AC_DEFUN([CF_WITH_PTHREAD],
6762 [
6763 AC_MSG_CHECKING(if you want to link with the pthread library)
6764 AC_ARG_WITH(pthread,
6765     [  --with-pthread          use POSIX thread library],
6766     [with_pthread=$withval],
6767     [with_pthread=no])
6768 AC_MSG_RESULT($with_pthread)
6769
6770 if test "$with_pthread" != no ; then
6771     AC_CHECK_HEADER(pthread.h,[
6772         AC_DEFINE(HAVE_PTHREADS_H)
6773
6774         for cf_lib_pthread in pthread c_r
6775         do
6776             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
6777             cf_save_LIBS="$LIBS"
6778             CF_ADD_LIB($cf_lib_pthread)
6779             AC_TRY_LINK([
6780 #include <pthread.h>
6781 ],[
6782                 int rc = pthread_create(0,0,0,0);
6783                 int r2 = pthread_mutexattr_settype(0, 0);
6784 ],[with_pthread=yes],[with_pthread=no])
6785             LIBS="$cf_save_LIBS"
6786             AC_MSG_RESULT($with_pthread)
6787             test "$with_pthread" = yes && break
6788         done
6789
6790         if test "$with_pthread" = yes ; then
6791             CF_ADD_LIB($cf_lib_pthread)
6792             AC_DEFINE(HAVE_LIBPTHREADS)
6793         else
6794             AC_MSG_ERROR(Cannot link with pthread library)
6795         fi
6796     ])
6797 fi
6798 ])
6799 dnl ---------------------------------------------------------------------------
6800 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
6801 dnl -------------------
6802 dnl Allow library's release-version to be overridden.  Generally this happens when a
6803 dnl packager has incremented the release-version past that used in the original package,
6804 dnl and wishes to keep doing this.
6805 dnl
6806 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
6807 dnl and {package}_MINOR symbols
6808 dnl symbol.
6809 AC_DEFUN([CF_WITH_REL_VERSION],[
6810 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
6811 AC_ARG_WITH(rel-version,
6812 [  --with-rel-version=XXX  override derived release version],
6813 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
6814  cf_cv_rel_version=$withval])
6815 ifelse($1,,[
6816  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
6817 ],[
6818  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
6819  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
6820  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
6821  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
6822 ])
6823 ])dnl
6824 dnl ---------------------------------------------------------------------------
6825 dnl CF_WITH_SYSMOUSE version: 2 updated: 2003/03/22 19:13:43
6826 dnl ----------------
6827 dnl If we can compile with sysmouse, make it available unless it is not wanted.
6828 AC_DEFUN([CF_WITH_SYSMOUSE],[
6829 # not everyone has "test -c"
6830 if test -c /dev/sysmouse 2>/dev/null ; then
6831 AC_MSG_CHECKING(if you want to use sysmouse)
6832 AC_ARG_WITH(sysmouse,
6833         [  --with-sysmouse         use sysmouse (FreeBSD console)],
6834         [cf_with_sysmouse=$withval],
6835         [cf_with_sysmouse=maybe])
6836         if test "$cf_with_sysmouse" != no ; then
6837         AC_TRY_COMPILE([
6838 #include <osreldate.h>
6839 #if (__FreeBSD_version >= 400017)
6840 #include <sys/consio.h>
6841 #include <sys/fbio.h>
6842 #else
6843 #include <machine/console.h>
6844 #endif
6845 ],[
6846         struct mouse_info the_mouse;
6847         ioctl(0, CONS_MOUSECTL, &the_mouse);
6848 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
6849         fi
6850 AC_MSG_RESULT($cf_with_sysmouse)
6851 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE)
6852 fi
6853 ])dnl
6854 dnl ---------------------------------------------------------------------------
6855 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
6856 dnl ----------------
6857 AC_DEFUN([CF_WITH_VALGRIND],[
6858 CF_NO_LEAKS_OPTION(valgrind,
6859         [  --with-valgrind         test: use valgrind],
6860         [USE_VALGRIND])
6861 ])dnl
6862 dnl ---------------------------------------------------------------------------
6863 dnl CF_XOPEN_SOURCE version: 42 updated: 2012/01/07 08:26:49
6864 dnl ---------------
6865 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
6866 dnl or adapt to the vendor's definitions to get equivalent functionality,
6867 dnl without losing the common non-POSIX features.
6868 dnl
6869 dnl Parameters:
6870 dnl     $1 is the nominal value for _XOPEN_SOURCE
6871 dnl     $2 is the nominal value for _POSIX_C_SOURCE
6872 AC_DEFUN([CF_XOPEN_SOURCE],[
6873
6874 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
6875 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
6876 cf_xopen_source=
6877
6878 case $host_os in #(vi
6879 aix[[4-7]]*) #(vi
6880         cf_xopen_source="-D_ALL_SOURCE"
6881         ;;
6882 cygwin) #(vi
6883         cf_XOPEN_SOURCE=600
6884         ;;
6885 darwin[[0-8]].*) #(vi
6886         cf_xopen_source="-D_APPLE_C_SOURCE"
6887         ;;
6888 darwin*) #(vi
6889         cf_xopen_source="-D_DARWIN_C_SOURCE"
6890         cf_XOPEN_SOURCE=
6891         ;;
6892 freebsd*|dragonfly*) #(vi
6893         # 5.x headers associate
6894         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
6895         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
6896         cf_POSIX_C_SOURCE=200112L
6897         cf_XOPEN_SOURCE=600
6898         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6899         ;;
6900 hpux11*) #(vi
6901         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
6902         ;;
6903 hpux*) #(vi
6904         cf_xopen_source="-D_HPUX_SOURCE"
6905         ;;
6906 irix[[56]].*) #(vi
6907         cf_xopen_source="-D_SGI_SOURCE"
6908         cf_XOPEN_SOURCE=
6909         ;;
6910 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
6911         CF_GNU_SOURCE
6912         ;;
6913 mirbsd*) #(vi
6914         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
6915         cf_XOPEN_SOURCE=
6916         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
6917         ;;
6918 netbsd*) #(vi
6919         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
6920         ;;
6921 openbsd[[4-9]]*) #(vi
6922         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
6923         cf_xopen_source="-D_BSD_SOURCE"
6924         cf_XOPEN_SOURCE=600
6925         ;;
6926 openbsd*) #(vi
6927         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
6928         ;;
6929 osf[[45]]*) #(vi
6930         cf_xopen_source="-D_OSF_SOURCE"
6931         ;;
6932 nto-qnx*) #(vi
6933         cf_xopen_source="-D_QNX_SOURCE"
6934         ;;
6935 sco*) #(vi
6936         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
6937         ;;
6938 solaris2.*) #(vi
6939         cf_xopen_source="-D__EXTENSIONS__"
6940         ;;
6941 *)
6942         CF_TRY_XOPEN_SOURCE
6943         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
6944         ;;
6945 esac
6946
6947 if test -n "$cf_xopen_source" ; then
6948         CF_ADD_CFLAGS($cf_xopen_source)
6949 fi
6950
6951 dnl In anything but the default case, we may have system-specific setting
6952 dnl which is still not guaranteed to provide all of the entrypoints that
6953 dnl _XOPEN_SOURCE would yield.
6954 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
6955         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
6956         AC_TRY_COMPILE([#include <stdlib.h>],[
6957 #ifndef _XOPEN_SOURCE
6958 make an error
6959 #endif],
6960         [cf_XOPEN_SOURCE_set=yes],
6961         [cf_XOPEN_SOURCE_set=no])
6962         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
6963         if test $cf_XOPEN_SOURCE_set = yes
6964         then
6965                 AC_TRY_COMPILE([#include <stdlib.h>],[
6966 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
6967 make an error
6968 #endif],
6969                 [cf_XOPEN_SOURCE_set_ok=yes],
6970                 [cf_XOPEN_SOURCE_set_ok=no])
6971                 if test $cf_XOPEN_SOURCE_set_ok = no
6972                 then
6973                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
6974                 fi
6975         else
6976                 CF_TRY_XOPEN_SOURCE
6977         fi
6978 fi
6979 ])