aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2012,2013 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.658 2013/03/12 13:40:56 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 3 updated: 2002/10/27 23:21:42
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54     [AC_TRY_LINK([#include <langinfo.h>],
  55       [char* cs = nl_langinfo(CODESET);],
  56       am_cv_langinfo_codeset=yes,
  57       am_cv_langinfo_codeset=no)
  58     ])
  59   if test $am_cv_langinfo_codeset = yes; then
  60     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62   fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ACVERSION_CHECK version: 4 updated: 2013/03/04 19:52:56
  66 dnl ------------------
  67 dnl Conditionally generate script according to whether we're using a given autoconf.
  68 dnl
  69 dnl $1 = version to compare against
  70 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  71 dnl $3 = code to use if AC_ACVERSION is older than $1.
  72 define([CF_ACVERSION_CHECK],
  73 [
  74 ifdef([AC_ACVERSION], ,[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])dnl
  75 ifdef([m4_version_compare],
  76 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  77 [CF_ACVERSION_COMPARE(
  78 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  79 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  80 dnl ---------------------------------------------------------------------------
  81 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  82 dnl --------------------
  83 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  84 dnl                      MAJOR2, MINOR2, TERNARY2,
  85 dnl                      PRINTABLE2, not FOUND, FOUND)
  86 define([CF_ACVERSION_COMPARE],
  87 [ifelse(builtin([eval], [$2 < $5]), 1,
  88 [ifelse([$8], , ,[$8])],
  89 [ifelse([$9], , ,[$9])])])dnl
  90 dnl ---------------------------------------------------------------------------
  91 dnl CF_ADA_INCLUDE_DIRS version: 6 updated: 2010/02/26 19:52:07
  92 dnl -------------------
  93 dnl Construct the list of include-options for the C programs in the Ada95
  94 dnl binding.
  95 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  96 [
  97 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  98 if test "$srcdir" != "."; then
  99         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 100 fi
 101 if test "$GCC" != yes; then
 102         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 103 elif test "$includedir" != "/usr/include"; then
 104         if test "$includedir" = '${prefix}/include' ; then
 105                 if test $prefix != /usr ; then
 106                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 107                 fi
 108         else
 109                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 110         fi
 111 fi
 112 AC_SUBST(ACPPFLAGS)
 113 ])dnl
 114 dnl ---------------------------------------------------------------------------
 115 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 116 dnl ---------------
 117 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 118 AC_DEFUN([CF_ADD_ADAFLAGS],[
 119         ADAFLAGS="$ADAFLAGS $1"
 120         AC_SUBST(ADAFLAGS)
 121 ])dnl
 122 dnl ---------------------------------------------------------------------------
 123 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
 124 dnl -------------
 125 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 126 dnl The second parameter if given makes this macro verbose.
 127 dnl
 128 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 129 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 130 dnl confused by the quotes (which require backslashes to keep them usable).
 131 AC_DEFUN([CF_ADD_CFLAGS],
 132 [
 133 cf_fix_cppflags=no
 134 cf_new_cflags=
 135 cf_new_cppflags=
 136 cf_new_extra_cppflags=
 137
 138 for cf_add_cflags in $1
 139 do
 140 case $cf_fix_cppflags in
 141 no)
 142         case $cf_add_cflags in #(vi
 143         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
 144                 case $cf_add_cflags in
 145                 -D*)
 146                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 147
 148                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 149                                 && test -z "${cf_tst_cflags}" \
 150                                 && cf_fix_cppflags=yes
 151
 152                         if test $cf_fix_cppflags = yes ; then
 153                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 154                                 continue
 155                         elif test "${cf_tst_cflags}" = "\"'" ; then
 156                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 157                                 continue
 158                         fi
 159                         ;;
 160                 esac
 161                 case "$CPPFLAGS" in
 162                 *$cf_add_cflags) #(vi
 163                         ;;
 164                 *) #(vi
 165                         case $cf_add_cflags in #(vi
 166                         -D*)
 167                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 168                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 169                                 ;;
 170                         esac
 171                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 172                         ;;
 173                 esac
 174                 ;;
 175         *)
 176                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 177                 ;;
 178         esac
 179         ;;
 180 yes)
 181         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 182
 183         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 184
 185         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 186                 && test -z "${cf_tst_cflags}" \
 187                 && cf_fix_cppflags=no
 188         ;;
 189 esac
 190 done
 191
 192 if test -n "$cf_new_cflags" ; then
 193         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 194         CFLAGS="$CFLAGS $cf_new_cflags"
 195 fi
 196
 197 if test -n "$cf_new_cppflags" ; then
 198         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 199         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 200 fi
 201
 202 if test -n "$cf_new_extra_cppflags" ; then
 203         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 204         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 205 fi
 206
 207 AC_SUBST(EXTRA_CPPFLAGS)
 208
 209 ])dnl
 210 dnl ---------------------------------------------------------------------------
 211 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 212 dnl -------------
 213 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 214 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 215 dnl but old versions (and some misinstalled ones) need that.  To make things
 216 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 217 dnl the include-path).
 218 AC_DEFUN([CF_ADD_INCDIR],
 219 [
 220 if test -n "$1" ; then
 221   for cf_add_incdir in $1
 222   do
 223         while test $cf_add_incdir != /usr/include
 224         do
 225           if test -d $cf_add_incdir
 226           then
 227                 cf_have_incdir=no
 228                 if test -n "$CFLAGS$CPPFLAGS" ; then
 229                   # a loop is needed to ensure we can add subdirs of existing dirs
 230                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 231                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 232                           cf_have_incdir=yes; break
 233                         fi
 234                   done
 235                 fi
 236
 237                 if test "$cf_have_incdir" = no ; then
 238                   if test "$cf_add_incdir" = /usr/local/include ; then
 239                         if test "$GCC" = yes
 240                         then
 241                           cf_save_CPPFLAGS=$CPPFLAGS
 242                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 243                           AC_TRY_COMPILE([#include <stdio.h>],
 244                                   [printf("Hello")],
 245                                   [],
 246                                   [cf_have_incdir=yes])
 247                           CPPFLAGS=$cf_save_CPPFLAGS
 248                         fi
 249                   fi
 250                 fi
 251
 252                 if test "$cf_have_incdir" = no ; then
 253                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 254                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 255
 256                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 257                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 258                   cf_add_incdir="$cf_top_incdir"
 259                 else
 260                   break
 261                 fi
 262           fi
 263         done
 264   done
 265 fi
 266 ])dnl
 267 dnl ---------------------------------------------------------------------------
 268 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 269 dnl ----------
 270 dnl Add a library, used to enforce consistency.
 271 dnl
 272 dnl $1 = library to add, without the "-l"
 273 dnl $2 = variable to update (default $LIBS)
 274 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 275 dnl ---------------------------------------------------------------------------
 276 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 277 dnl -------------
 278 dnl     Adds to the library-path
 279 dnl
 280 dnl     Some machines have trouble with multiple -L options.
 281 dnl
 282 dnl $1 is the (list of) directory(s) to add
 283 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 284 dnl
 285 AC_DEFUN([CF_ADD_LIBDIR],
 286 [
 287 if test -n "$1" ; then
 288   for cf_add_libdir in $1
 289   do
 290     if test $cf_add_libdir = /usr/lib ; then
 291       :
 292     elif test -d $cf_add_libdir
 293     then
 294       cf_have_libdir=no
 295       if test -n "$LDFLAGS$LIBS" ; then
 296         # a loop is needed to ensure we can add subdirs of existing dirs
 297         for cf_test_libdir in $LDFLAGS $LIBS ; do
 298           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 299             cf_have_libdir=yes; break
 300           fi
 301         done
 302       fi
 303       if test "$cf_have_libdir" = no ; then
 304         CF_VERBOSE(adding $cf_add_libdir to library-path)
 305         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 306       fi
 307     fi
 308   done
 309 fi
 310 ])dnl
 311 dnl ---------------------------------------------------------------------------
 312 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 313 dnl -----------
 314 dnl Add one or more libraries, used to enforce consistency.
 315 dnl
 316 dnl $1 = libraries to add, with the "-l", etc.
 317 dnl $2 = variable to update (default $LIBS)
 318 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 319 dnl ---------------------------------------------------------------------------
 320 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
 321 dnl ------------------
 322 dnl Append to a search-list for a nonstandard header/lib-file
 323 dnl     $1 = the variable to return as result
 324 dnl     $2 = the package name
 325 dnl     $3 = the subdirectory, e.g., bin, include or lib
 326 dnl $4 = the directory under which we will test for subdirectories
 327 dnl $5 = a directory that we do not want $4 to match
 328 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 329 [
 330 test "$4" != "$5" && \
 331 test -d "$4" && \
 332 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
 333         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 334         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 335         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 336         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 337         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 338         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 339 }
 340 ])dnl
 341 dnl ---------------------------------------------------------------------------
 342 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 343 dnl --------------
 344 dnl Allow user to disable a normally-on option.
 345 AC_DEFUN([CF_ARG_DISABLE],
 346 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 347 dnl ---------------------------------------------------------------------------
 348 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 349 dnl -------------
 350 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 351 dnl values.
 352 dnl
 353 dnl Parameters:
 354 dnl $1 = option name
 355 dnl $2 = help-string
 356 dnl $3 = action to perform if option is not default
 357 dnl $4 = action if perform if option is default
 358 dnl $5 = default option value (either 'yes' or 'no')
 359 AC_DEFUN([CF_ARG_OPTION],
 360 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 361   if test "$enableval" != "$5" ; then
 362 ifelse([$3],,[    :]dnl
 363 ,[    $3]) ifelse([$4],,,[
 364   else
 365     $4])
 366   fi],[enableval=$5 ifelse([$4],,,[
 367   $4
 368 ])dnl
 369   ])])dnl
 370 dnl ---------------------------------------------------------------------------
 371 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 372 dnl -----------
 373 dnl Check for suitable "ar" (archiver) options for updating an archive.
 374 AC_DEFUN([CF_AR_FLAGS],[
 375 AC_REQUIRE([CF_PROG_AR])
 376
 377 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 378         cf_cv_ar_flags=unknown
 379         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 380         do
 381
 382                 # check if $ARFLAGS already contains this choice
 383                 if test "x$ARFLAGS" != "x" ; then
 384                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 385                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 386                                 cf_cv_ar_flags=
 387                                 break
 388                         fi
 389                 fi
 390
 391                 rm -f conftest.$ac_cv_objext
 392                 rm -f conftest.a
 393
 394                 cat >conftest.$ac_ext <<EOF
 395 #line __oline__ "configure"
 396 int     testdata[[3]] = { 123, 456, 789 };
 397 EOF
 398                 if AC_TRY_EVAL(ac_compile) ; then
 399                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 400                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 401                         if test -f conftest.a ; then
 402                                 cf_cv_ar_flags=$cf_ar_flags
 403                                 break
 404                         fi
 405                 else
 406                         CF_VERBOSE(cannot compile test-program)
 407                         break
 408                 fi
 409         done
 410         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 411 ])
 412
 413 if test -n "$ARFLAGS" ; then
 414         if test -n "$cf_cv_ar_flags" ; then
 415                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 416         fi
 417 else
 418         ARFLAGS=$cf_cv_ar_flags
 419 fi
 420
 421 AC_SUBST(ARFLAGS)
 422 ])
 423 dnl ---------------------------------------------------------------------------
 424 dnl CF_AWK_BIG_PRINTF version: 4 updated: 2011/10/30 17:09:50
 425 dnl -----------------
 426 dnl Check if awk can handle big strings using printf.  Some older versions of
 427 dnl awk choke on large strings passed via "%s".
 428 dnl
 429 dnl $1 = desired string size
 430 dnl $2 = variable to set with result
 431 AC_DEFUN([CF_AWK_BIG_PRINTF],
 432 [
 433         case x$AWK in #(vi
 434         x)
 435                 eval $2=no
 436                 ;;
 437         *) #(vi
 438                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 439                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 440                         eval $2=yes
 441                 else
 442                         eval $2=no
 443                 fi
 444                 ;;
 445         esac
 446 ])dnl
 447 dnl ---------------------------------------------------------------------------
 448 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 449 dnl ------------
 450 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 451 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 452 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 453 dnl
 454 dnl Treat the configuration-variable specially here, since we're directly
 455 dnl substituting its value (i.e., 1/0).
 456 dnl
 457 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 458 AC_DEFUN([CF_BOOL_DECL],
 459 [
 460 AC_MSG_CHECKING(if we should include stdbool.h)
 461
 462 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 463         AC_TRY_COMPILE([],[bool foo = false],
 464                 [cf_cv_header_stdbool_h=0],
 465                 [AC_TRY_COMPILE([
 466 #ifndef __BEOS__
 467 #include <stdbool.h>
 468 #endif
 469 ],[bool foo = false],
 470                         [cf_cv_header_stdbool_h=1],
 471                         [cf_cv_header_stdbool_h=0])])])
 472
 473 if test "$cf_cv_header_stdbool_h" = 1
 474 then    AC_MSG_RESULT(yes)
 475 else    AC_MSG_RESULT(no)
 476 fi
 477
 478 AC_MSG_CHECKING([for builtin bool type])
 479
 480 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 481         AC_TRY_COMPILE([
 482 #include <stdio.h>
 483 #include <sys/types.h>
 484 ],[bool x = false],
 485                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 486                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 487         ])
 488
 489 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 490 then    AC_MSG_RESULT(yes)
 491 else    AC_MSG_RESULT(no)
 492 fi
 493 ])dnl
 494 dnl ---------------------------------------------------------------------------
 495 dnl CF_BOOL_SIZE version: 12 updated: 2006/12/16 12:33:30
 496 dnl ------------
 497 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 498 dnl Don't bother looking for bool.h, since it's been deprecated.
 499 dnl
 500 dnl If the current compiler is C rather than C++, we get the bool definition
 501 dnl from <stdbool.h>.
 502 AC_DEFUN([CF_BOOL_SIZE],
 503 [
 504 AC_MSG_CHECKING([for size of bool])
 505 AC_CACHE_VAL(cf_cv_type_of_bool,[
 506         rm -f cf_test.out
 507         AC_TRY_RUN([
 508 #include <stdlib.h>
 509 #include <stdio.h>
 510
 511 #if defined(__cplusplus)
 512
 513 #ifdef HAVE_GXX_BUILTIN_H
 514 #include <g++/builtin.h>
 515 #elif HAVE_GPP_BUILTIN_H
 516 #include <gpp/builtin.h>
 517 #elif HAVE_BUILTIN_H
 518 #include <builtin.h>
 519 #endif
 520
 521 #else
 522
 523 #if $cf_cv_header_stdbool_h
 524 #include <stdbool.h>
 525 #endif
 526
 527 #endif
 528
 529 main()
 530 {
 531         FILE *fp = fopen("cf_test.out", "w");
 532         if (fp != 0) {
 533                 bool x = true;
 534                 if ((bool)(-x) >= 0)
 535                         fputs("unsigned ", fp);
 536                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 537                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 538                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 539                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 540                 fclose(fp);
 541         }
 542         ${cf_cv_main_return:-return}(0);
 543 }
 544                 ],
 545                 [cf_cv_type_of_bool=`cat cf_test.out`
 546                  if test -z "$cf_cv_type_of_bool"; then
 547                    cf_cv_type_of_bool=unknown
 548                  fi],
 549                 [cf_cv_type_of_bool=unknown],
 550                 [cf_cv_type_of_bool=unknown])
 551         ])
 552         rm -f cf_test.out
 553 AC_MSG_RESULT($cf_cv_type_of_bool)
 554 if test "$cf_cv_type_of_bool" = unknown ; then
 555         case .$NCURSES_BOOL in #(vi
 556         .auto|.) NCURSES_BOOL=unsigned;;
 557         esac
 558         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 559         cf_cv_type_of_bool=$NCURSES_BOOL
 560 fi
 561 ])dnl
 562 dnl ---------------------------------------------------------------------------
 563 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 564 dnl -----------
 565 dnl If we're cross-compiling, allow the user to override the tools and their
 566 dnl options.  The configure script is oriented toward identifying the host
 567 dnl compiler, etc., but we need a build compiler to generate parts of the
 568 dnl source.
 569 dnl
 570 dnl $1 = default for $CPPFLAGS
 571 dnl $2 = default for $LIBS
 572 AC_DEFUN([CF_BUILD_CC],[
 573 CF_ACVERSION_CHECK(2.52,,
 574         [AC_REQUIRE([CF_PROG_EXT])])
 575 if test "$cross_compiling" = yes ; then
 576
 577         # defaults that we might want to override
 578         : ${BUILD_CFLAGS:=''}
 579         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 580         : ${BUILD_LDFLAGS:=''}
 581         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 582         : ${BUILD_EXEEXT:='$x'}
 583         : ${BUILD_OBJEXT:='o'}
 584
 585         AC_ARG_WITH(build-cc,
 586                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 587                 [BUILD_CC="$withval"],
 588                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 589         AC_MSG_CHECKING(for native build C compiler)
 590         AC_MSG_RESULT($BUILD_CC)
 591
 592         AC_MSG_CHECKING(for native build C preprocessor)
 593         AC_ARG_WITH(build-cpp,
 594                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 595                 [BUILD_CPP="$withval"],
 596                 [BUILD_CPP='${BUILD_CC} -E'])
 597         AC_MSG_RESULT($BUILD_CPP)
 598
 599         AC_MSG_CHECKING(for native build C flags)
 600         AC_ARG_WITH(build-cflags,
 601                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 602                 [BUILD_CFLAGS="$withval"])
 603         AC_MSG_RESULT($BUILD_CFLAGS)
 604
 605         AC_MSG_CHECKING(for native build C preprocessor-flags)
 606         AC_ARG_WITH(build-cppflags,
 607                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 608                 [BUILD_CPPFLAGS="$withval"])
 609         AC_MSG_RESULT($BUILD_CPPFLAGS)
 610
 611         AC_MSG_CHECKING(for native build linker-flags)
 612         AC_ARG_WITH(build-ldflags,
 613                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 614                 [BUILD_LDFLAGS="$withval"])
 615         AC_MSG_RESULT($BUILD_LDFLAGS)
 616
 617         AC_MSG_CHECKING(for native build linker-libraries)
 618         AC_ARG_WITH(build-libs,
 619                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 620                 [BUILD_LIBS="$withval"])
 621         AC_MSG_RESULT($BUILD_LIBS)
 622
 623         # this assumes we're on Unix.
 624         BUILD_EXEEXT=
 625         BUILD_OBJEXT=o
 626
 627         : ${BUILD_CC:='${CC}'}
 628
 629         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 630                 AC_MSG_ERROR([Cross-build requires two compilers.
 631 Use --with-build-cc to specify the native compiler.])
 632         fi
 633
 634 else
 635         : ${BUILD_CC:='${CC}'}
 636         : ${BUILD_CPP:='${CPP}'}
 637         : ${BUILD_CFLAGS:='${CFLAGS}'}
 638         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 639         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 640         : ${BUILD_LIBS:='${LIBS}'}
 641         : ${BUILD_EXEEXT:='$x'}
 642         : ${BUILD_OBJEXT:='o'}
 643 fi
 644
 645 AC_SUBST(BUILD_CC)
 646 AC_SUBST(BUILD_CPP)
 647 AC_SUBST(BUILD_CFLAGS)
 648 AC_SUBST(BUILD_CPPFLAGS)
 649 AC_SUBST(BUILD_LDFLAGS)
 650 AC_SUBST(BUILD_LIBS)
 651 AC_SUBST(BUILD_EXEEXT)
 652 AC_SUBST(BUILD_OBJEXT)
 653 ])dnl
 654 dnl ---------------------------------------------------------------------------
 655 dnl CF_CC_ENV_FLAGS version: 1 updated: 2012/10/03 05:25:49
 656 dnl ---------------
 657 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 658 dnl into CC.  This will not help with broken scripts that wrap the compiler with
 659 dnl options, but eliminates a more common category of user confusion.
 660 AC_DEFUN([CF_CC_ENV_FLAGS],
 661 [
 662 # This should have been defined by AC_PROG_CC
 663 : ${CC:=cc}
 664
 665 AC_MSG_CHECKING(\$CC variable)
 666 case "$CC" in #(vi
 667 *[[\ \  ]]-[[IUD]]*)
 668         AC_MSG_RESULT(broken)
 669         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 670         # humor him...
 671         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 672         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 673         CF_ADD_CFLAGS($cf_flags)
 674         ;;
 675 *)
 676         AC_MSG_RESULT(ok)
 677         ;;
 678 esac
 679 ])dnl
 680 dnl ---------------------------------------------------------------------------
 681 dnl CF_CFG_DEFAULTS version: 8 updated: 2011/06/04 20:09:13
 682 dnl ---------------
 683 dnl Determine the default configuration into which we'll install ncurses.  This
 684 dnl can be overridden by the user's command-line options.  There's two items to
 685 dnl look for:
 686 dnl     1. the prefix (e.g., /usr)
 687 dnl     2. the header files (e.g., /usr/include/ncurses)
 688 dnl We'll look for a previous installation of ncurses and use the same defaults.
 689 dnl
 690 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 691 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 692 dnl programs from a vendor's.
 693 AC_DEFUN([CF_CFG_DEFAULTS],
 694 [
 695 AC_MSG_CHECKING(for prefix)
 696 if test "x$prefix" = "xNONE" ; then
 697         case "$cf_cv_system_name" in
 698                 # non-vendor systems don't have a conflict
 699         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|k*bsd*-gnu)
 700                 prefix=/usr
 701                 ;;
 702         *)      prefix=$ac_default_prefix
 703                 ;;
 704         esac
 705 fi
 706 AC_MSG_RESULT($prefix)
 707
 708 if test "x$prefix" = "xNONE" ; then
 709 AC_MSG_CHECKING(for default include-directory)
 710 test -n "$verbose" && echo 1>&AC_FD_MSG
 711 for cf_symbol in \
 712         $includedir \
 713         $includedir/ncurses \
 714         $prefix/include \
 715         $prefix/include/ncurses \
 716         /usr/local/include \
 717         /usr/local/include/ncurses \
 718         /usr/include \
 719         /usr/include/ncurses
 720 do
 721         cf_dir=`eval echo $cf_symbol`
 722         if test -f $cf_dir/curses.h ; then
 723         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 724                 includedir="$cf_symbol"
 725                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 726                 break
 727         fi
 728         fi
 729         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 730 done
 731 AC_MSG_RESULT($includedir)
 732 fi
 733 ])dnl
 734 dnl ---------------------------------------------------------------------------
 735 dnl CF_CGETENT version: 5 updated: 2012/10/06 17:56:13
 736 dnl ----------
 737 dnl Check if the terminal-capability database functions are available.  If not,
 738 dnl ncurses has a much-reduced version.
 739 AC_DEFUN([CF_CGETENT],[
 740 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 741 AC_TRY_LINK([
 742 #include <stdlib.h>],[
 743         char temp[128];
 744         char *buf = temp;
 745         char *db_array = temp;
 746         cgetent(&buf, &db_array, "vt100");
 747         cgetcap(buf, "tc", '=');
 748         cgetmatch(buf, "tc");
 749         ],
 750         [cf_cv_cgetent=yes],
 751         [cf_cv_cgetent=no])
 752 ])
 753
 754 if test "$cf_cv_cgetent" = yes
 755 then
 756         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 757 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 758 AC_TRY_LINK([
 759 #include <stdlib.h>],[
 760         char temp[128];
 761         char *buf = temp;
 762 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 763         const char *db_array = temp;
 764         cgetent(&buf, &db_array, "vt100");
 765 #endif
 766         cgetcap(buf, "tc", '=');
 767         cgetmatch(buf, "tc");
 768         ],
 769         [cf_cv_cgetent_const=yes],
 770         [cf_cv_cgetent_const=no])
 771 ])
 772         if test "$cf_cv_cgetent_const" = yes
 773         then
 774                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 775         fi
 776 fi
 777 ])dnl
 778 dnl ---------------------------------------------------------------------------
 779 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 780 dnl --------------
 781 dnl Check if we're accidentally using a cache from a different machine.
 782 dnl Derive the system name, as a check for reusing the autoconf cache.
 783 dnl
 784 dnl If we've packaged config.guess and config.sub, run that (since it does a
 785 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 786 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 787 dnl which is useful in cross-compiles.
 788 dnl
 789 dnl Note: we would use $ac_config_sub, but that is one of the places where
 790 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 791 AC_DEFUN([CF_CHECK_CACHE],
 792 [
 793 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 794         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 795         system_name="$host_os"
 796 else
 797         system_name="`(uname -s -r) 2>/dev/null`"
 798         if test -z "$system_name" ; then
 799                 system_name="`(hostname) 2>/dev/null`"
 800         fi
 801 fi
 802 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 803 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 804
 805 test -z "$system_name" && system_name="$cf_cv_system_name"
 806 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 807
 808 if test ".$system_name" != ".$cf_cv_system_name" ; then
 809         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 810         AC_MSG_ERROR("Please remove config.cache and try again.")
 811 fi
 812 ])dnl
 813 dnl ---------------------------------------------------------------------------
 814 dnl CF_CHECK_ERRNO version: 11 updated: 2010/05/26 05:38:42
 815 dnl --------------
 816 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 817 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 818 dnl ourselves.
 819 dnl
 820 dnl $1 = the name to check
 821 dnl $2 = the assumed type
 822 AC_DEFUN([CF_CHECK_ERRNO],
 823 [
 824 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 825     AC_TRY_COMPILE([
 826 #ifdef HAVE_STDLIB_H
 827 #include <stdlib.h>
 828 #endif
 829 #include <stdio.h>
 830 #include <sys/types.h>
 831 #include <errno.h> ],
 832     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 833     [cf_cv_dcl_$1=yes],
 834     [cf_cv_dcl_$1=no])
 835 ])
 836
 837 if test "$cf_cv_dcl_$1" = no ; then
 838     CF_UPPER(cf_result,decl_$1)
 839     AC_DEFINE_UNQUOTED($cf_result)
 840 fi
 841
 842 # It's possible (for near-UNIX clones) that the data doesn't exist
 843 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 844 ])dnl
 845 dnl ---------------------------------------------------------------------------
 846 dnl CF_CHECK_EXTERN_DATA version: 3 updated: 2001/12/30 18:03:23
 847 dnl --------------------
 848 dnl Check for existence of external data in the current set of libraries.  If
 849 dnl we can modify it, it's real enough.
 850 dnl $1 = the name to check
 851 dnl $2 = its type
 852 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 853 [
 854 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 855     AC_TRY_LINK([
 856 #undef $1
 857 extern $2 $1;
 858 ],
 859     [$1 = 2],
 860     [cf_cv_have_$1=yes],
 861     [cf_cv_have_$1=no])
 862 ])
 863
 864 if test "$cf_cv_have_$1" = yes ; then
 865     CF_UPPER(cf_result,have_$1)
 866     AC_DEFINE_UNQUOTED($cf_result)
 867 fi
 868
 869 ])dnl
 870 dnl ---------------------------------------------------------------------------
 871 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 872 dnl -------------------
 873 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 874 dnl is not "weak" - warn about this because it can create problems linking
 875 dnl applications with ncurses.
 876 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 877 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 878
 879 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 880 cf_cv_check_gpm_wgetch=unknown
 881 if test "$cross_compiling" != yes ; then
 882
 883 cat >conftest.$ac_ext <<CF_EOF
 884 #include <gpm.h>
 885 int main()
 886 {
 887         Gpm_Wgetch();
 888         ${cf_cv_main_return:-return}(0);
 889 }
 890 CF_EOF
 891
 892         cf_save_LIBS="$LIBS"
 893         # This only works if we can look at the symbol table.  If a shared
 894         # library is stripped for install, we cannot use that.  So we're forced
 895         # to rely on the static library, noting that some packagers may not
 896         # include it.
 897         LIBS="-static -lgpm -dynamic $LIBS"
 898         if AC_TRY_EVAL(ac_compile) ; then
 899                 if AC_TRY_EVAL(ac_link) ; then
 900                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 901                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 902                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 903                 fi
 904         fi
 905         rm -rf conftest*
 906         LIBS="$cf_save_LIBS"
 907 fi
 908 ])
 909
 910 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 911         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 912 fi
 913 ])])dnl
 914 dnl ---------------------------------------------------------------------------
 915 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
 916 dnl ----------------
 917 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
 918 AC_DEFUN([CF_CHECK_WCHAR_H],[
 919 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
 920 AC_TRY_COMPILE(
 921 [
 922 #include <stdlib.h>
 923 #include <wchar.h>
 924 ],[
 925         wint_t foo = 0;
 926         int bar = iswpunct(foo)],
 927         [cf_cv_wchar_h_okay=yes],
 928         [cf_cv_wchar_h_okay=no])])
 929
 930 if test $cf_cv_wchar_h_okay = no
 931 then
 932         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 933 fi
 934 ])dnl
 935 dnl ---------------------------------------------------------------------------
 936 dnl CF_CLANG_COMPILER version: 1 updated: 2012/06/16 14:55:39
 937 dnl -----------------
 938 dnl Check if the given compiler is really clang.  clang's C driver defines
 939 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 940 dnl not ignore some gcc options.
 941 dnl
 942 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 943 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 944 dnl the wrappers for gcc and g++ warnings.
 945 dnl
 946 dnl $1 = GCC (default) or GXX
 947 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
 948 dnl $3 = CFLAGS (default) or CXXFLAGS
 949 AC_DEFUN([CF_CLANG_COMPILER],[
 950 ifelse([$2],,CLANG_COMPILER,[$2])=no
 951
 952 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 953         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 954         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 955         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
 956         AC_TRY_COMPILE([],[
 957 #ifdef __clang__
 958 #else
 959 make an error
 960 #endif
 961 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 962 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
 963 ],[])
 964         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 965         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 966 fi
 967 ])
 968 dnl ---------------------------------------------------------------------------
 969 dnl CF_CPP_PARAM_INIT version: 6 updated: 2012/10/06 17:56:13
 970 dnl -----------------
 971 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
 972 dnl is a late feature for the standard and is not in some recent compilers
 973 dnl (1999/9/11).
 974 AC_DEFUN([CF_CPP_PARAM_INIT],
 975 [
 976 if test -n "$CXX"; then
 977 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
 978         AC_LANG_SAVE
 979         AC_LANG_CPLUSPLUS
 980         AC_TRY_RUN([
 981 class TEST {
 982 private:
 983         int value;
 984 public:
 985         TEST(int x = 1);
 986         ~TEST();
 987 };
 988
 989 TEST::TEST(int x = 1)   // some compilers do not like second initializer
 990 {
 991         value = x;
 992 }
 993 int main() { }
 994 ],
 995         [cf_cv_cpp_param_init=yes],
 996         [cf_cv_cpp_param_init=no],
 997         [cf_cv_cpp_param_init=unknown])
 998         AC_LANG_RESTORE
 999 ])
1000 fi
1001 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1002 ])dnl
1003 dnl ---------------------------------------------------------------------------
1004 dnl CF_CPP_STATIC_CAST version: 2 updated: 2012/10/06 17:56:13
1005 dnl ------------------
1006 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1007 dnl not be supported in g++ before 3.0
1008 AC_DEFUN([CF_CPP_STATIC_CAST],
1009 [
1010 if test -n "$CXX"; then
1011
1012 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1013         AC_LANG_SAVE
1014         AC_LANG_CPLUSPLUS
1015
1016         AC_TRY_COMPILE([
1017 class NCursesPanel
1018 {
1019 public:
1020   NCursesPanel(int nlines,
1021                int ncols,
1022                int begin_y = 0,
1023                int begin_x = 0)
1024   {
1025   }
1026
1027   ~NCursesPanel();
1028 };
1029
1030 template<class T> class NCursesUserPanel : public NCursesPanel
1031 {
1032 public:
1033   NCursesUserPanel (int nlines,
1034                     int ncols,
1035                     int begin_y = 0,
1036                     int begin_x = 0,
1037                     const T* p_UserData = static_cast<T*>(0))
1038     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1039   {
1040   };
1041   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1042   {
1043   };
1044
1045   virtual ~NCursesUserPanel() {};
1046 };
1047 ],[
1048         const char* p_UserData = static_cast<char*>(0)],
1049         [cf_cv_cpp_static_cast=yes],
1050         [cf_cv_cpp_static_cast=no])
1051
1052         AC_LANG_RESTORE
1053 ])
1054
1055 fi
1056
1057 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1058 ])dnl
1059 dnl ---------------------------------------------------------------------------
1060 dnl CF_CXX_AR_FLAGS version: 1 updated: 2011/10/29 08:35:34
1061 dnl ---------------
1062 dnl Setup special archiver flags for given compilers.
1063 AC_DEFUN([CF_CXX_AR_FLAGS],[
1064         CXX_AR='$(AR)'
1065         CXX_ARFLAGS='$(ARFLAGS)'
1066         case $cf_cv_system_name in #(vi
1067         irix*) #(vi
1068             if test "$GXX" != yes ; then
1069                 CXX_AR='$(CXX)'
1070                 CXX_ARFLAGS='-ar -o'
1071             fi
1072             ;;
1073         sco3.2v5*) #(vi
1074             CXXLDFLAGS="-u main"
1075             ;;
1076         solaris2*)
1077             if test "$GXX" != yes ; then
1078                 CXX_AR='$(CXX)'
1079                 CXX_ARFLAGS='-xar -o'
1080             fi
1081             ;;
1082         esac
1083         AC_SUBST(CXXLDFLAGS)
1084         AC_SUBST(CXX_AR)
1085         AC_SUBST(CXX_ARFLAGS)
1086 ])dnl
1087 dnl ---------------------------------------------------------------------------
1088 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1089 dnl -------------------------
1090 dnl For c++, check if iostream uses "std::" namespace.
1091 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1092 AC_CHECK_HEADERS(iostream)
1093 if test x"$ac_cv_header_iostream" = xyes ; then
1094         AC_MSG_CHECKING(if iostream uses std-namespace)
1095         AC_TRY_COMPILE([
1096 #include <iostream>
1097 using std::endl;
1098 using std::cerr;],[
1099 cerr << "testing" << endl;
1100 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1101         AC_MSG_RESULT($cf_iostream_namespace)
1102         if test "$cf_iostream_namespace" = yes ; then
1103                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1104         fi
1105 fi
1106 ])dnl
1107 dnl ---------------------------------------------------------------------------
1108 dnl CF_C_INLINE version: 4 updated: 2012/06/16 14:55:39
1109 dnl -----------
1110 dnl Check if the C compiler supports "inline".
1111 dnl $1 is the name of a shell variable to set if inline is supported
1112 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1113 AC_DEFUN([CF_C_INLINE],[
1114 AC_C_INLINE
1115 $1=
1116 if test "$ac_cv_c_inline" != no ; then
1117   $1=inline
1118   if test "$INTEL_COMPILER" = yes
1119   then
1120     :
1121   elif test "$CLANG_COMPILER" = yes
1122   then
1123     :
1124   elif test "$GCC" = yes
1125   then
1126     AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1127       cf_save_CFLAGS=$CFLAGS
1128       CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1129       AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1130       [${cf_cv_main_return:-return} foo()],
1131       [cf_cv_gcc_inline=yes],
1132       [cf_cv_gcc_inline=no])
1133       CFLAGS=$cf_save_CFLAGS
1134     ])
1135     if test "$cf_cv_gcc_inline" = yes ; then
1136         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1137     fi
1138   fi
1139 fi
1140 AC_SUBST($1)
1141 ])dnl
1142 dnl ---------------------------------------------------------------------------
1143 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1144 dnl ----------
1145 dnl "dirname" is not portable, so we fake it with a shell script.
1146 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1147 dnl ---------------------------------------------------------------------------
1148 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1149 dnl ---------------
1150 AC_DEFUN([CF_DIRS_TO_MAKE],
1151 [
1152 DIRS_TO_MAKE="lib"
1153 for cf_item in $cf_list_models
1154 do
1155         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1156         for cf_item2 in $DIRS_TO_MAKE
1157         do
1158                 test $cf_item2 = $cf_subdir && break
1159         done
1160         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1161 done
1162 for cf_dir in $DIRS_TO_MAKE
1163 do
1164         test ! -d $cf_dir && mkdir $cf_dir
1165 done
1166 AC_SUBST(DIRS_TO_MAKE)
1167 ])dnl
1168 dnl ---------------------------------------------------------------------------
1169 dnl CF_DISABLE_ECHO version: 12 updated: 2012/10/06 16:30:28
1170 dnl ---------------
1171 dnl You can always use "make -n" to see the actual options, but it's hard to
1172 dnl pick out/analyze warning messages when the compile-line is long.
1173 dnl
1174 dnl Sets:
1175 dnl     ECHO_LT - symbol to control if libtool is verbose
1176 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1177 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1178 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1179 dnl     ECHO_CC - symbol to put before any "cc" line
1180 dnl
1181 AC_DEFUN([CF_DISABLE_ECHO],[
1182 AC_MSG_CHECKING(if you want to see long compiling messages)
1183 CF_ARG_DISABLE(echo,
1184         [  --disable-echo          do not display "compiling" commands],
1185         [
1186     ECHO_LT='--silent'
1187     ECHO_LD='@echo linking [$]@;'
1188     RULE_CC='@echo compiling [$]<'
1189     SHOW_CC='@echo compiling [$]@'
1190     ECHO_CC='@'
1191 ],[
1192     ECHO_LT=''
1193     ECHO_LD=''
1194     RULE_CC=''
1195     SHOW_CC=''
1196     ECHO_CC=''
1197 ])
1198 AC_MSG_RESULT($enableval)
1199 AC_SUBST(ECHO_LT)
1200 AC_SUBST(ECHO_LD)
1201 AC_SUBST(RULE_CC)
1202 AC_SUBST(SHOW_CC)
1203 AC_SUBST(ECHO_CC)
1204 ])dnl
1205 dnl ---------------------------------------------------------------------------
1206 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1207 dnl ----------------
1208 dnl Combine no-leak checks with the libraries or tools that are used for the
1209 dnl checks.
1210 AC_DEFUN([CF_DISABLE_LEAKS],[
1211
1212 AC_REQUIRE([CF_WITH_DMALLOC])
1213 AC_REQUIRE([CF_WITH_DBMALLOC])
1214 AC_REQUIRE([CF_WITH_VALGRIND])
1215
1216 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1217 AC_ARG_ENABLE(leaks,
1218         [  --disable-leaks         test: free permanent memory, analyze leaks],
1219         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1220         : ${with_no_leaks:=no})
1221 AC_MSG_RESULT($with_no_leaks)
1222
1223 if test "$with_no_leaks" = yes ; then
1224         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1225         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1226 fi
1227 ])dnl
1228 dnl ---------------------------------------------------------------------------
1229 dnl CF_DISABLE_LIBTOOL_VERSION version: 1 updated: 2010/05/15 15:45:59
1230 dnl --------------------------
1231 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1232 dnl the older "-version-info" feature.  The newer feature allows us to use
1233 dnl version numbering on shared libraries which make them compatible with
1234 dnl various systems.
1235 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1236 [
1237 AC_MSG_CHECKING(if libtool -version-number should be used)
1238 CF_ARG_DISABLE(libtool-version,
1239         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1240         [cf_libtool_version=no],
1241         [cf_libtool_version=yes])
1242 AC_MSG_RESULT($cf_libtool_version)
1243
1244 if test "$cf_libtool_version" = yes ; then
1245         LIBTOOL_VERSION="-version-number"
1246 else
1247         LIBTOOL_VERSION="-version-info"
1248 fi
1249
1250 AC_SUBST(LIBTOOL_VERSION)
1251 ])dnl
1252 dnl ---------------------------------------------------------------------------
1253 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1254 dnl ---------------------
1255 dnl The rpath-hack makes it simpler to build programs, particularly with the
1256 dnl *BSD ports which may have essential libraries in unusual places.  But it
1257 dnl can interfere with building an executable for the base system.  Use this
1258 dnl option in that case.
1259 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1260 [
1261 AC_MSG_CHECKING(if rpath-hack should be disabled)
1262 CF_ARG_DISABLE(rpath-hack,
1263         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1264         [cf_disable_rpath_hack=yes],
1265         [cf_disable_rpath_hack=no])
1266 AC_MSG_RESULT($cf_disable_rpath_hack)
1267 if test "$cf_disable_rpath_hack" = no ; then
1268         CF_RPATH_HACK
1269 fi
1270 ])
1271 dnl ---------------------------------------------------------------------------
1272 dnl CF_ENABLE_PC_FILES version: 9 updated: 2012/08/04 13:59:54
1273 dnl ------------------
1274 dnl This is the "--enable-pc-files" option, which is available if there is a
1275 dnl pkg-config configuration on the local machine.
1276 AC_DEFUN([CF_ENABLE_PC_FILES],[
1277 AC_REQUIRE([CF_PKG_CONFIG])
1278 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1279
1280 if test "$PKG_CONFIG" != none ; then
1281         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1282         AC_ARG_ENABLE(pc-files,
1283                 [  --enable-pc-files       generate and install .pc files for pkg-config],
1284                 [enable_pc_files=$enableval],
1285                 [enable_pc_files=no])
1286         AC_MSG_RESULT($enable_pc_files)
1287         if test "$enable_pc_files" != no
1288         then
1289                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1290         fi
1291 else
1292         enable_pc_files=no
1293 fi
1294 ])dnl
1295 dnl ---------------------------------------------------------------------------
1296 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1297 dnl ---------------
1298 dnl Check if the rpath option should be used, setting cache variable
1299 dnl cf_cv_enable_rpath if so.
1300 AC_DEFUN([CF_ENABLE_RPATH],
1301 [
1302 AC_MSG_CHECKING(if rpath option should be used)
1303 AC_ARG_ENABLE(rpath,
1304 [  --enable-rpath          use rpath option when generating shared libraries],
1305 [cf_cv_enable_rpath=$enableval],
1306 [cf_cv_enable_rpath=no])
1307 AC_MSG_RESULT($cf_cv_enable_rpath)
1308 ])dnl
1309 dnl ---------------------------------------------------------------------------
1310 dnl CF_ENABLE_STRING_HACKS version: 3 updated: 2013/01/26 16:26:12
1311 dnl ----------------------
1312 dnl On a few platforms, the compiler and/or loader nags with untruthful
1313 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1314 dnl and implying that most uses of the recommended alternatives are correct.
1315 dnl
1316 dnl Factually speaking, no one has actually counted the number of uses of these
1317 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1318 dnl instances are meaningless compared to the hundreds of millions of lines of
1319 dnl existing C code.
1320 dnl
1321 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1322 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1323 dnl standard - but evolved through phases, and older implementations are likely
1324 dnl to yield surprising results, as documented in manpages on various systems.
1325 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1326 [
1327 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1328 AC_ARG_ENABLE(string-hacks,
1329         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1330         [with_string_hacks=$enableval],
1331         [with_string_hacks=no])
1332 AC_MSG_RESULT($with_string_hacks)
1333
1334 if test "x$with_string_hacks" = "xyes"; then
1335         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1336         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1337         AC_CHECK_FUNCS( strlcat strlcpy snprintf )
1338 fi
1339 ])dnl
1340 dnl ---------------------------------------------------------------------------
1341 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1342 dnl --------
1343 dnl Check if 'errno' is declared in <errno.h>
1344 AC_DEFUN([CF_ERRNO],
1345 [
1346 CF_CHECK_ERRNO(errno)
1347 ])dnl
1348 dnl ---------------------------------------------------------------------------
1349 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1350 dnl ---------------
1351 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1352 dnl math.h and builtin.h, only for ncurses
1353 AC_DEFUN([CF_ETIP_DEFINES],
1354 [
1355 AC_MSG_CHECKING(for special defines needed for etip.h)
1356 cf_save_CXXFLAGS="$CXXFLAGS"
1357 cf_result="none"
1358
1359 # etip.h includes ncurses.h which includes ncurses_dll.h
1360 # But ncurses_dll.h is generated - fix here.
1361 test -d include || mkdir include
1362 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1363
1364 for cf_math in "" MATH_H
1365 do
1366 for cf_excp in "" MATH_EXCEPTION
1367 do
1368         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1369         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1370         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1371 AC_TRY_COMPILE([
1372 #include <etip.h.in>
1373 ],[],[
1374         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1375         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1376         cf_result="$cf_math $cf_excp"
1377         break 2
1378 ],[])
1379 done
1380 done
1381 AC_MSG_RESULT($cf_result)
1382 CXXFLAGS="$cf_save_CXXFLAGS"
1383 ])
1384 dnl ---------------------------------------------------------------------------
1385 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1386 dnl ---------------
1387 dnl Find a library (specifically the linkage used in the code fragment),
1388 dnl searching for it if it is not already in the library path.
1389 dnl See also CF_ADD_SEARCHPATH.
1390 dnl
1391 dnl Parameters (4-on are optional):
1392 dnl     $1 = headers for library entrypoint
1393 dnl     $2 = code fragment for library entrypoint
1394 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1395 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1396 dnl     $5 = action to perform if not successful
1397 dnl     $6 = module name, if not the same as the library name
1398 dnl     $7 = extra libraries
1399 dnl
1400 dnl Sets these variables:
1401 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1402 dnl     $cf_cv_header_path_$3 - include-directory if needed
1403 dnl     $cf_cv_library_path_$3 - library-directory if needed
1404 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1405 AC_DEFUN([CF_FIND_LINKAGE],[
1406
1407 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1408 # will be set on completion of the AC_TRY_LINK below.
1409 cf_cv_header_path_$3=
1410 cf_cv_library_path_$3=
1411
1412 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1413
1414 cf_save_LIBS="$LIBS"
1415
1416 AC_TRY_LINK([$1],[$2],[
1417         cf_cv_find_linkage_$3=yes
1418         cf_cv_header_path_$3=/usr/include
1419         cf_cv_library_path_$3=/usr/lib
1420 ],[
1421
1422 LIBS="-l$3 $7 $cf_save_LIBS"
1423
1424 AC_TRY_LINK([$1],[$2],[
1425         cf_cv_find_linkage_$3=yes
1426         cf_cv_header_path_$3=/usr/include
1427         cf_cv_library_path_$3=/usr/lib
1428         cf_cv_library_file_$3="-l$3"
1429 ],[
1430         cf_cv_find_linkage_$3=no
1431         LIBS="$cf_save_LIBS"
1432
1433     CF_VERBOSE(find linkage for $3 library)
1434     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1435
1436     cf_save_CPPFLAGS="$CPPFLAGS"
1437     cf_test_CPPFLAGS="$CPPFLAGS"
1438
1439     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1440     for cf_cv_header_path_$3 in $cf_search
1441     do
1442       if test -d $cf_cv_header_path_$3 ; then
1443         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1444         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1445         AC_TRY_COMPILE([$1],[$2],[
1446             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1447             cf_cv_find_linkage_$3=maybe
1448             cf_test_CPPFLAGS="$CPPFLAGS"
1449             break],[
1450             CPPFLAGS="$cf_save_CPPFLAGS"
1451             ])
1452       fi
1453     done
1454
1455     if test "$cf_cv_find_linkage_$3" = maybe ; then
1456
1457       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1458
1459       cf_save_LIBS="$LIBS"
1460       cf_save_LDFLAGS="$LDFLAGS"
1461
1462       ifelse([$6],,,[
1463         CPPFLAGS="$cf_test_CPPFLAGS"
1464         LIBS="-l$3 $7 $cf_save_LIBS"
1465         AC_TRY_LINK([$1],[$2],[
1466             CF_VERBOSE(... found $3 library in system)
1467             cf_cv_find_linkage_$3=yes])
1468             CPPFLAGS="$cf_save_CPPFLAGS"
1469             LIBS="$cf_save_LIBS"
1470             ])
1471
1472       if test "$cf_cv_find_linkage_$3" != yes ; then
1473         CF_LIBRARY_PATH(cf_search,$3)
1474         for cf_cv_library_path_$3 in $cf_search
1475         do
1476           if test -d $cf_cv_library_path_$3 ; then
1477             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1478             CPPFLAGS="$cf_test_CPPFLAGS"
1479             LIBS="-l$3 $7 $cf_save_LIBS"
1480             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1481             AC_TRY_LINK([$1],[$2],[
1482                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1483                 cf_cv_find_linkage_$3=yes
1484                 cf_cv_library_file_$3="-l$3"
1485                 break],[
1486                 CPPFLAGS="$cf_save_CPPFLAGS"
1487                 LIBS="$cf_save_LIBS"
1488                 LDFLAGS="$cf_save_LDFLAGS"
1489                 ])
1490           fi
1491         done
1492         CPPFLAGS="$cf_save_CPPFLAGS"
1493         LDFLAGS="$cf_save_LDFLAGS"
1494       fi
1495
1496     else
1497       cf_cv_find_linkage_$3=no
1498     fi
1499     ],$7)
1500 ])
1501
1502 LIBS="$cf_save_LIBS"
1503
1504 if test "$cf_cv_find_linkage_$3" = yes ; then
1505 ifelse([$4],,[
1506         CF_ADD_INCDIR($cf_cv_header_path_$3)
1507         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1508         CF_ADD_LIB($3)
1509 ],[$4])
1510 else
1511 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1512 fi
1513 ])dnl
1514 dnl ---------------------------------------------------------------------------
1515 dnl CF_FIXUP_ADAFLAGS version: 1 updated: 2012/03/31 18:48:10
1516 dnl -----------------
1517 dnl make ADAFLAGS consistent with CFLAGS
1518 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1519         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1520         case "$CFLAGS" in
1521         *-g*)
1522                 CF_ADD_ADAFLAGS(-g)
1523                 ;;
1524         esac
1525         case "$CFLAGS" in
1526         *-O*)
1527                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1528                 CF_ADD_ADAFLAGS($cf_O_flag)
1529                 ;;
1530         esac
1531         AC_MSG_RESULT($ADAFLAGS)
1532 ])dnl
1533 dnl ---------------------------------------------------------------------------
1534 dnl CF_FUNC_DLSYM version: 3 updated: 2012/10/06 11:17:15
1535 dnl -------------
1536 dnl Test for dlsym() and related functions, as well as libdl.
1537 dnl
1538 dnl Sets
1539 dnl     $cf_have_dlsym
1540 dnl     $cf_have_libdl
1541 AC_DEFUN([CF_FUNC_DLSYM],[
1542 cf_have_dlsym=no
1543 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1544
1545 cf_have_libdl=no
1546 AC_CHECK_LIB(dl,dlsym,[
1547         cf_have_dlsym=yes
1548         cf_have_libdl=yes])])
1549
1550 if test "$cf_have_dlsym" = yes ; then
1551         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1552
1553         AC_MSG_CHECKING(whether able to link to dl*() functions)
1554         AC_TRY_LINK([#include <dlfcn.h>],[
1555                 void *obj;
1556                 if ((obj = dlopen("filename", 0)) != 0) {
1557                         if (dlsym(obj, "symbolname") == 0) {
1558                         dlclose(obj);
1559                         }
1560                 }],[
1561                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1562                 AC_MSG_ERROR(Cannot link test program for libdl)])
1563         AC_MSG_RESULT(ok)
1564 else
1565         AC_MSG_ERROR(Cannot find dlsym function)
1566 fi
1567 ])
1568 dnl ---------------------------------------------------------------------------
1569 dnl CF_FUNC_MEMMOVE version: 8 updated: 2012/10/04 20:12:20
1570 dnl ---------------
1571 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1572 dnl is found, add our own version of memmove to the list of objects.
1573 AC_DEFUN([CF_FUNC_MEMMOVE],
1574 [
1575 AC_CHECK_FUNC(memmove,,[
1576 AC_CHECK_FUNC(bcopy,[
1577         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1578                 AC_TRY_RUN([
1579 int main() {
1580         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1581         char temp[40];
1582         bcopy(data, temp, sizeof(data));
1583         bcopy(temp+10, temp, 15);
1584         bcopy(temp+5, temp+15, 10);
1585         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1586 }
1587                 ],
1588                 [cf_cv_good_bcopy=yes],
1589                 [cf_cv_good_bcopy=no],
1590                 [cf_cv_good_bcopy=unknown])
1591                 ])
1592         ],[cf_cv_good_bcopy=no])
1593         if test "$cf_cv_good_bcopy" = yes ; then
1594                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1595         else
1596                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1597         fi
1598 ])])dnl
1599 dnl ---------------------------------------------------------------------------
1600 dnl CF_FUNC_NANOSLEEP version: 4 updated: 2012/10/06 17:56:13
1601 dnl -----------------
1602 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1603 dnl AIX 4.x, provide a non-working version.
1604 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1605 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1606 AC_TRY_RUN([
1607 #include <stdio.h>
1608 #include <errno.h>
1609 #include <time.h>
1610
1611 #ifdef HAVE_SYS_TIME_H
1612 #include <sys/time.h>
1613 #endif
1614
1615 int main() {
1616         struct timespec ts1, ts2;
1617         int code;
1618         ts1.tv_sec  = 0;
1619         ts1.tv_nsec = 750000000;
1620         ts2.tv_sec  = 0;
1621         ts2.tv_nsec = 0;
1622         errno = 0;
1623         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1624         ${cf_cv_main_return:-return}(code != 0);
1625 }
1626 ],
1627         [cf_cv_func_nanosleep=yes],
1628         [cf_cv_func_nanosleep=no],
1629         [cf_cv_func_nanosleep=unknown])])
1630
1631 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1632 ])
1633 dnl ---------------------------------------------------------------------------
1634 dnl CF_FUNC_OPENPTY version: 3 updated: 2010/05/29 16:31:02
1635 dnl ---------------
1636 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1637 dnl "util" library as well.
1638 AC_DEFUN([CF_FUNC_OPENPTY],
1639 [
1640 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1641 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1642     cf_save_LIBS="$LIBS"
1643     test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1644     for cf_header in pty.h libutil.h util.h
1645     do
1646     AC_TRY_LINK([
1647 #include <$cf_header>
1648 ],[
1649     int x = openpty((int *)0, (int *)0, (char *)0,
1650                    (struct termios *)0, (struct winsize *)0);
1651 ],[
1652         cf_cv_func_openpty=$cf_header
1653         break
1654 ],[
1655         cf_cv_func_openpty=no
1656 ])
1657     done
1658     LIBS="$cf_save_LIBS"
1659 ])
1660 ])dnl
1661 dnl ---------------------------------------------------------------------------
1662 dnl CF_FUNC_POLL version: 8 updated: 2012/10/04 05:24:07
1663 dnl ------------
1664 dnl See if the poll function really works.  Some platforms have poll(), but
1665 dnl it does not work for terminals or files.
1666 AC_DEFUN([CF_FUNC_POLL],[
1667 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1668 AC_TRY_RUN([
1669 #include <stdlib.h>
1670 #include <stdio.h>
1671 #include <unistd.h>
1672 #include <fcntl.h>
1673 #ifdef HAVE_POLL_H
1674 #include <poll.h>
1675 #else
1676 #include <sys/poll.h>
1677 #endif
1678 int main() {
1679         struct pollfd myfds;
1680         int ret;
1681
1682         /* check for Darwin bug with respect to "devices" */
1683         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
1684         if (myfds.fd < 0)
1685                 myfds.fd = 0;
1686         myfds.events = POLLIN;
1687         myfds.revents = 0;
1688
1689         ret = poll(&myfds, 1, 100);
1690
1691         if (ret < 0 || (myfds.revents & POLLNVAL)) {
1692                 ret = -1;
1693         } else {
1694                 int fd = 0;
1695                 if (!isatty(fd)) {
1696                         fd = open("/dev/tty", 2);       /* O_RDWR */
1697                 }
1698
1699                 if (fd >= 0) {
1700                         /* also check with standard input */
1701                         myfds.fd = fd;
1702                         myfds.events = POLLIN;
1703                         myfds.revents = 0;
1704                         ret = poll(&myfds, 1, 100);
1705                 } else {
1706                         ret = -1;
1707                 }
1708         }
1709         ${cf_cv_main_return:-return}(ret < 0);
1710 }],
1711         [cf_cv_working_poll=yes],
1712         [cf_cv_working_poll=no],
1713         [cf_cv_working_poll=unknown])])
1714 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
1715 ])dnl
1716 dnl ---------------------------------------------------------------------------
1717 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
1718 dnl ---------------
1719 dnl Some old/broken variations define tcgetattr() only as a macro in
1720 dnl termio(s).h
1721 AC_DEFUN([CF_FUNC_TERMIOS],[
1722 AC_REQUIRE([CF_STRUCT_TERMIOS])
1723 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1724 AC_TRY_LINK([
1725 #include <sys/types.h>
1726 #ifdef HAVE_UNISTD_H
1727 #include <unistd.h>
1728 #endif
1729 #ifdef HAVE_TERMIOS_H
1730 #include <termios.h>
1731 #define TTY struct termios
1732 #else
1733 #ifdef HAVE_TERMIO_H
1734 #include <termio.h>
1735 #define TTY struct termio
1736 #endif
1737 #endif
1738 ],[
1739 TTY foo;
1740 tcgetattr(1, &foo);],
1741 [cf_cv_have_tcgetattr=yes],
1742 [cf_cv_have_tcgetattr=no])])
1743 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
1744 ])dnl
1745 dnl ---------------------------------------------------------------------------
1746 dnl CF_FUNC_VSSCANF version: 4 updated: 2012/10/06 17:56:13
1747 dnl ---------------
1748 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1749 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1750 dnl other functions.
1751 AC_DEFUN([CF_FUNC_VSSCANF],
1752 [
1753 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1754 AC_TRY_LINK([
1755 #include <stdarg.h>
1756 #include <stdio.h>],[
1757         va_list ap;
1758         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1759 AC_TRY_LINK([
1760 #include <stdarg.h>
1761 #include <stdio.h>],[
1762     FILE strbuf;
1763     char *str = "from";
1764
1765     strbuf._flag = _IOREAD;
1766     strbuf._ptr = strbuf._base = (unsigned char *) str;
1767     strbuf._cnt = strlen(str);
1768     strbuf._file = _NFILE;
1769     return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1770 AC_TRY_LINK([
1771 #include <stdarg.h>
1772 #include <stdio.h>],[
1773     FILE strbuf;
1774     char *str = "from";
1775
1776     strbuf._flag = _IOREAD;
1777     strbuf._ptr = strbuf._base = (unsigned char *) str;
1778     strbuf._cnt = strlen(str);
1779     strbuf._file = _NFILE;
1780     return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1781 cf_cv_func_vsscanf=no])])])])
1782
1783 case $cf_cv_func_vsscanf in #(vi
1784 vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);; #(vi
1785 vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);; #(vi
1786 _doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
1787 esac
1788
1789 ])dnl
1790 dnl ---------------------------------------------------------------------------
1791 dnl CF_GCC_ATTRIBUTES version: 16 updated: 2012/10/02 20:55:03
1792 dnl -----------------
1793 dnl Test for availability of useful gcc __attribute__ directives to quiet
1794 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1795 dnl to documentation, unrecognized directives cause older compilers to barf.
1796 AC_DEFUN([CF_GCC_ATTRIBUTES],
1797 [
1798 if test "$GCC" = yes
1799 then
1800 cat > conftest.i <<EOF
1801 #ifndef GCC_PRINTF
1802 #define GCC_PRINTF 0
1803 #endif
1804 #ifndef GCC_SCANF
1805 #define GCC_SCANF 0
1806 #endif
1807 #ifndef GCC_NORETURN
1808 #define GCC_NORETURN /* nothing */
1809 #endif
1810 #ifndef GCC_UNUSED
1811 #define GCC_UNUSED /* nothing */
1812 #endif
1813 EOF
1814 if test "$GCC" = yes
1815 then
1816         AC_CHECKING([for $CC __attribute__ directives])
1817 cat > conftest.$ac_ext <<EOF
1818 #line __oline__ "${as_me:-configure}"
1819 #include "confdefs.h"
1820 #include "conftest.h"
1821 #include "conftest.i"
1822 #if     GCC_PRINTF
1823 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1824 #else
1825 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1826 #endif
1827 #if     GCC_SCANF
1828 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1829 #else
1830 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1831 #endif
1832 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1833 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1834 extern void foo(void) GCC_NORETURN;
1835 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1836 EOF
1837         cf_printf_attribute=no
1838         cf_scanf_attribute=no
1839         for cf_attribute in scanf printf unused noreturn
1840         do
1841                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1842                 cf_directive="__attribute__(($cf_attribute))"
1843                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1844
1845                 case $cf_attribute in #(vi
1846                 printf) #(vi
1847                         cf_printf_attribute=yes
1848                         cat >conftest.h <<EOF
1849 #define GCC_$cf_ATTRIBUTE 1
1850 EOF
1851                         ;;
1852                 scanf) #(vi
1853                         cf_scanf_attribute=yes
1854                         cat >conftest.h <<EOF
1855 #define GCC_$cf_ATTRIBUTE 1
1856 EOF
1857                         ;;
1858                 *) #(vi
1859                         cat >conftest.h <<EOF
1860 #define GCC_$cf_ATTRIBUTE $cf_directive
1861 EOF
1862                         ;;
1863                 esac
1864
1865                 if AC_TRY_EVAL(ac_compile); then
1866                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1867                         cat conftest.h >>confdefs.h
1868                         case $cf_attribute in #(vi
1869                         noreturn) #(vi
1870                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1871                                 ;;
1872                         printf) #(vi
1873                                 cf_value='/* nothing */'
1874                                 if test "$cf_printf_attribute" != no ; then
1875                                         cf_value='__attribute__((format(printf,fmt,var)))'
1876                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1877                                 fi
1878                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1879                                 ;;
1880                         scanf) #(vi
1881                                 cf_value='/* nothing */'
1882                                 if test "$cf_scanf_attribute" != no ; then
1883                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1884                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1885                                 fi
1886                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1887                                 ;;
1888                         unused) #(vi
1889                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1890                                 ;;
1891                         esac
1892                 fi
1893         done
1894 else
1895         fgrep define conftest.i >>confdefs.h
1896 fi
1897 rm -rf conftest*
1898 fi
1899 ])dnl
1900 dnl ---------------------------------------------------------------------------
1901 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1902 dnl --------------
1903 dnl Find version of gcc
1904 AC_DEFUN([CF_GCC_VERSION],[
1905 AC_REQUIRE([AC_PROG_CC])
1906 GCC_VERSION=none
1907 if test "$GCC" = yes ; then
1908         AC_MSG_CHECKING(version of $CC)
1909         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1910         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1911         AC_MSG_RESULT($GCC_VERSION)
1912 fi
1913 ])dnl
1914 dnl ---------------------------------------------------------------------------
1915 dnl CF_GCC_WARNINGS version: 29 updated: 2012/06/16 14:55:39
1916 dnl ---------------
1917 dnl Check if the compiler supports useful warning options.  There's a few that
1918 dnl we don't use, simply because they're too noisy:
1919 dnl
1920 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1921 dnl     -Wredundant-decls (system headers make this too noisy)
1922 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1923 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1924 dnl             is enabled for ncurses using "--enable-const".
1925 dnl     -pedantic
1926 dnl
1927 dnl Parameter:
1928 dnl     $1 is an optional list of gcc warning flags that a particular
1929 dnl             application might want to use, e.g., "no-unused" for
1930 dnl             -Wno-unused
1931 dnl Special:
1932 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1933 dnl
1934 AC_DEFUN([CF_GCC_WARNINGS],
1935 [
1936 AC_REQUIRE([CF_GCC_VERSION])
1937 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1938 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1939
1940 cat > conftest.$ac_ext <<EOF
1941 #line __oline__ "${as_me:-configure}"
1942 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1943 EOF
1944
1945 if test "$INTEL_COMPILER" = yes
1946 then
1947 # The "-wdXXX" options suppress warnings:
1948 # remark #1419: external declaration in primary source file
1949 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1950 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1951 # remark #193: zero used for undefined preprocessing identifier
1952 # remark #593: variable "curs_sb_left_arrow" was set but never used
1953 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1954 # remark #869: parameter "tw" was never referenced
1955 # remark #981: operands are evaluated in unspecified order
1956 # warning #279: controlling expression is constant
1957
1958         AC_CHECKING([for $CC warning options])
1959         cf_save_CFLAGS="$CFLAGS"
1960         EXTRA_CFLAGS="-Wall"
1961         for cf_opt in \
1962                 wd1419 \
1963                 wd1683 \
1964                 wd1684 \
1965                 wd193 \
1966                 wd593 \
1967                 wd279 \
1968                 wd810 \
1969                 wd869 \
1970                 wd981
1971         do
1972                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1973                 if AC_TRY_EVAL(ac_compile); then
1974                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1975                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1976                 fi
1977         done
1978         CFLAGS="$cf_save_CFLAGS"
1979
1980 elif test "$GCC" = yes
1981 then
1982         AC_CHECKING([for $CC warning options])
1983         cf_save_CFLAGS="$CFLAGS"
1984         EXTRA_CFLAGS=
1985         cf_warn_CONST=""
1986         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1987         for cf_opt in W Wall \
1988                 Wbad-function-cast \
1989                 Wcast-align \
1990                 Wcast-qual \
1991                 Winline \
1992                 Wmissing-declarations \
1993                 Wmissing-prototypes \
1994                 Wnested-externs \
1995                 Wpointer-arith \
1996                 Wshadow \
1997                 Wstrict-prototypes \
1998                 Wundef $cf_warn_CONST $1
1999         do
2000                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2001                 if AC_TRY_EVAL(ac_compile); then
2002                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2003                         case $cf_opt in #(vi
2004                         Wcast-qual) #(vi
2005                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2006                                 ;;
2007                         Winline) #(vi
2008                                 case $GCC_VERSION in
2009                                 [[34]].*)
2010                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2011                                         continue;;
2012                                 esac
2013                                 ;;
2014                         Wpointer-arith) #(vi
2015                                 case $GCC_VERSION in
2016                                 [[12]].*)
2017                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2018                                         continue;;
2019                                 esac
2020                                 ;;
2021                         esac
2022                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2023                 fi
2024         done
2025         CFLAGS="$cf_save_CFLAGS"
2026 fi
2027 rm -rf conftest*
2028
2029 AC_SUBST(EXTRA_CFLAGS)
2030 ])dnl
2031 dnl ---------------------------------------------------------------------------
2032 dnl CF_GETOPT_HEADER version: 5 updated: 2012/10/06 16:39:58
2033 dnl ----------------
2034 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2035 dnl unistd.h or (nonstandard) in getopt.h
2036 AC_DEFUN([CF_GETOPT_HEADER],
2037 [
2038 AC_HAVE_HEADERS(unistd.h getopt.h)
2039 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2040 cf_cv_getopt_header=none
2041 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2042 do
2043 AC_TRY_COMPILE([
2044 #include <$cf_header>],
2045 [int x = optind; char *y = optarg],
2046 [cf_cv_getopt_header=$cf_header
2047  break])
2048 done
2049 ])
2050 if test $cf_cv_getopt_header != none ; then
2051         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if we need to include getopt.h])
2052 fi
2053 ])dnl
2054 dnl ---------------------------------------------------------------------------
2055 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
2056 dnl ----------------
2057 AC_DEFUN([CF_GNAT_GENERICS],
2058 [
2059 AC_REQUIRE([CF_GNAT_VERSION])
2060
2061 AC_MSG_CHECKING(if GNAT supports generics)
2062 case $cf_gnat_version in #(vi
2063 3.[[1-9]]*|[[4-9]].*) #(vi
2064         cf_gnat_generics=yes
2065         ;;
2066 *)
2067         cf_gnat_generics=no
2068         ;;
2069 esac
2070 AC_MSG_RESULT($cf_gnat_generics)
2071
2072 if test "$cf_gnat_generics" = yes
2073 then
2074         cf_compile_generics=generics
2075         cf_generic_objects="\${GENOBJS}"
2076 else
2077         cf_compile_generics=
2078         cf_generic_objects=
2079 fi
2080
2081 AC_SUBST(cf_compile_generics)
2082 AC_SUBST(cf_generic_objects)
2083 ])dnl
2084 dnl ---------------------------------------------------------------------------
2085 dnl CF_GNAT_PRAGMA_UNREF version: 1 updated: 2010/06/19 15:22:18
2086 dnl --------------------
2087 dnl Check if the gnat pragma "Unreferenced" works.
2088 AC_DEFUN([CF_GNAT_PRAGMA_UNREF],[
2089 AC_CACHE_CHECK(if GNAT pragma Unreferenced works,cf_cv_pragma_unreferenced,[
2090 CF_GNAT_TRY_LINK([procedure conftest;],
2091 [with Text_IO;
2092 with GNAT.OS_Lib;
2093 procedure conftest is
2094    test : Integer;
2095    pragma Unreferenced (test);
2096 begin
2097    test := 1;
2098    Text_IO.Put ("Hello World");
2099    Text_IO.New_Line;
2100    GNAT.OS_Lib.OS_Exit (0);
2101 end conftest;],
2102         [cf_cv_pragma_unreferenced=yes],
2103         [cf_cv_pragma_unreferenced=no])])
2104
2105 # if the pragma is supported, use it (needed in the Trace code).
2106 if test $cf_cv_pragma_unreferenced = yes ; then
2107         PRAGMA_UNREF=TRUE
2108 else
2109         PRAGMA_UNREF=FALSE
2110 fi
2111 AC_SUBST(PRAGMA_UNREF)
2112 ])dnl
2113 dnl ---------------------------------------------------------------------------
2114 dnl CF_GNAT_PROJECTS version: 2 updated: 2011/03/23 20:24:41
2115 dnl ----------------
2116 dnl GNAT projects are configured with ".gpr" project files.
2117 dnl GNAT libraries are a further development, using the project feature.
2118 AC_DEFUN([CF_GNAT_PROJECTS],
2119 [
2120 AC_REQUIRE([CF_GNAT_VERSION])
2121
2122 cf_gnat_libraries=no
2123 cf_gnat_projects=no
2124
2125 AC_MSG_CHECKING(if GNAT supports project files)
2126 case $cf_gnat_version in #(vi
2127 3.[[0-9]]*) #(vi
2128         ;;
2129 *)
2130         case $cf_cv_system_name in #(vi
2131         cygwin*) #(vi
2132                 ;;
2133         *)
2134                 mkdir conftest.src conftest.bin conftest.lib
2135                 cd conftest.src
2136                 rm -rf conftest* *~conftest*
2137                 cat >>library.gpr <<CF_EOF
2138 project Library is
2139   Kind := External ("LIB_KIND");
2140   for Library_Name use "ConfTest";
2141   for Object_Dir use ".";
2142   for Library_ALI_Dir use External("LIBRARY_DIR");
2143   for Library_Version use External ("SONAME");
2144   for Library_Kind use Kind;
2145   for Library_Dir use External("BUILD_DIR");
2146   Source_Dir := External ("SOURCE_DIR");
2147   for Source_Dirs use (Source_Dir);
2148   package Compiler is
2149      for Default_Switches ("Ada") use
2150        ("-g",
2151         "-O2",
2152         "-gnatafno",
2153         "-gnatVa",   -- All validity checks
2154         "-gnatwa");  -- Activate all optional errors
2155   end Compiler;
2156 end Library;
2157 CF_EOF
2158                 cat >>confpackage.ads <<CF_EOF
2159 package ConfPackage is
2160    procedure conftest;
2161 end ConfPackage;
2162 CF_EOF
2163                 cat >>confpackage.adb <<CF_EOF
2164 with Text_IO;
2165 package body ConfPackage is
2166    procedure conftest is
2167    begin
2168       Text_IO.Put ("Hello World");
2169       Text_IO.New_Line;
2170    end conftest;
2171 end ConfPackage;
2172 CF_EOF
2173                 if ( $cf_ada_make $ADAFLAGS \
2174                                 -Plibrary.gpr \
2175                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2176                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2177                                 -XSOURCE_DIR=`pwd` \
2178                                 -XSONAME=libConfTest.so.1 \
2179                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2180                         cf_gnat_projects=yes
2181                 fi
2182                 cd ..
2183                 if test -f conftest.lib/confpackage.ali
2184                 then
2185                         cf_gnat_libraries=yes
2186                 fi
2187                 rm -rf conftest* *~conftest*
2188                 ;;
2189         esac
2190         ;;
2191 esac
2192 AC_MSG_RESULT($cf_gnat_projects)
2193
2194 if test $cf_gnat_projects = yes
2195 then
2196         AC_MSG_CHECKING(if GNAT supports libraries)
2197         AC_MSG_RESULT($cf_gnat_libraries)
2198 fi
2199
2200 if test "$cf_gnat_projects" = yes
2201 then
2202         USE_OLD_MAKERULES="#"
2203         USE_GNAT_PROJECTS=""
2204 else
2205         USE_OLD_MAKERULES=""
2206         USE_GNAT_PROJECTS="#"
2207 fi
2208
2209 if test "$cf_gnat_libraries" = yes
2210 then
2211         USE_GNAT_LIBRARIES=""
2212 else
2213         USE_GNAT_LIBRARIES="#"
2214 fi
2215
2216 AC_SUBST(USE_OLD_MAKERULES)
2217 AC_SUBST(USE_GNAT_PROJECTS)
2218 AC_SUBST(USE_GNAT_LIBRARIES)
2219 ])dnl
2220 dnl ---------------------------------------------------------------------------
2221 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2222 dnl --------------
2223 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2224 dnl is noted that gnat may compile a tasking unit even for configurations which
2225 dnl fail at runtime.
2226 AC_DEFUN([CF_GNAT_SIGINT],[
2227 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2228 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2229
2230 package ConfTest is
2231
2232    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2233    pragma Unreserve_All_Interrupts;
2234    pragma Warnings (On);
2235
2236    protected Process is
2237       procedure Stop;
2238       function Continue return Boolean;
2239       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2240    private
2241       Done : Boolean := False;
2242    end Process;
2243
2244 end ConfTest;],
2245 [package body ConfTest is
2246    protected body Process is
2247       procedure Stop is
2248       begin
2249          Done := True;
2250       end Stop;
2251       function Continue return Boolean is
2252       begin
2253          return not Done;
2254       end Continue;
2255    end Process;
2256 end ConfTest;],
2257         [cf_cv_gnat_sigint=yes],
2258         [cf_cv_gnat_sigint=no])])
2259
2260 if test $cf_cv_gnat_sigint = yes ; then
2261         USE_GNAT_SIGINT=""
2262 else
2263         USE_GNAT_SIGINT="#"
2264 fi
2265 AC_SUBST(USE_GNAT_SIGINT)
2266 ])dnl
2267 dnl ---------------------------------------------------------------------------
2268 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2269 dnl ----------------
2270 dnl Verify that a test program compiles/links with GNAT.
2271 dnl $cf_ada_make is set to the program that compiles/links
2272 dnl $ADAFLAGS may be set to the GNAT flags.
2273 dnl
2274 dnl $1 is the text of the spec
2275 dnl $2 is the text of the body
2276 dnl $3 is the shell command to execute if successful
2277 dnl $4 is the shell command to execute if not successful
2278 AC_DEFUN([CF_GNAT_TRY_LINK],
2279 [
2280 rm -rf conftest* *~conftest*
2281 cat >>conftest.ads <<CF_EOF
2282 $1
2283 CF_EOF
2284 cat >>conftest.adb <<CF_EOF
2285 $2
2286 CF_EOF
2287 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2288 ifelse($3,,      :,[      $3])
2289 ifelse($4,,,[else
2290    $4])
2291 fi
2292 rm -rf conftest* *~conftest*
2293 ])dnl
2294 dnl ---------------------------------------------------------------------------
2295 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2296 dnl ---------------
2297 dnl Verify that a test program compiles and runs with GNAT
2298 dnl $cf_ada_make is set to the program that compiles/links
2299 dnl $ADAFLAGS may be set to the GNAT flags.
2300 dnl
2301 dnl $1 is the text of the spec
2302 dnl $2 is the text of the body
2303 dnl $3 is the shell command to execute if successful
2304 dnl $4 is the shell command to execute if not successful
2305 AC_DEFUN([CF_GNAT_TRY_RUN],
2306 [
2307 rm -rf conftest* *~conftest*
2308 cat >>conftest.ads <<CF_EOF
2309 $1
2310 CF_EOF
2311 cat >>conftest.adb <<CF_EOF
2312 $2
2313 CF_EOF
2314 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2315    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2316 ifelse($3,,      :,[      $3])
2317 ifelse($4,,,[   else
2318       $4])
2319    fi
2320 ifelse($4,,,[else
2321    $4])
2322 fi
2323 rm -rf conftest* *~conftest*
2324 ])dnl
2325 dnl ---------------------------------------------------------------------------
2326 dnl CF_GNAT_VERSION version: 18 updated: 2012/01/21 19:28:10
2327 dnl ---------------
2328 dnl Verify version of GNAT.
2329 AC_DEFUN([CF_GNAT_VERSION],
2330 [
2331 AC_MSG_CHECKING(for gnat version)
2332 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2333         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2334     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2335 AC_MSG_RESULT($cf_gnat_version)
2336
2337 case $cf_gnat_version in #(vi
2338 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]]) #(vi
2339         cf_cv_prog_gnat_correct=yes
2340         ;;
2341 *)
2342         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2343         cf_cv_prog_gnat_correct=no
2344         ;;
2345 esac
2346 ])
2347 dnl ---------------------------------------------------------------------------
2348 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2349 dnl -------------
2350 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2351 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2352 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2353 dnl since it is interwoven with GNU extensions.
2354 dnl
2355 dnl Well, yes we could work around it...
2356 AC_DEFUN([CF_GNU_SOURCE],
2357 [
2358 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2359 AC_TRY_COMPILE([#include <sys/types.h>],[
2360 #ifndef _XOPEN_SOURCE
2361 make an error
2362 #endif],
2363         [cf_cv_gnu_source=no],
2364         [cf_save="$CPPFLAGS"
2365          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2366          AC_TRY_COMPILE([#include <sys/types.h>],[
2367 #ifdef _XOPEN_SOURCE
2368 make an error
2369 #endif],
2370         [cf_cv_gnu_source=no],
2371         [cf_cv_gnu_source=yes])
2372         CPPFLAGS="$cf_save"
2373         ])
2374 ])
2375 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2376 ])dnl
2377 dnl ---------------------------------------------------------------------------
2378 dnl CF_GPP_LIBRARY version: 11 updated: 2012/10/06 17:56:13
2379 dnl --------------
2380 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2381 dnl problem :-).  If we have the compiler but no library, we'll be able to
2382 dnl configure, but won't be able to build the c++ demo program.
2383 AC_DEFUN([CF_GPP_LIBRARY],
2384 [
2385 cf_cxx_library=unknown
2386 case $cf_cv_system_name in #(vi
2387 os2*) #(vi
2388         cf_gpp_libname=gpp
2389         ;;
2390 *)
2391         cf_gpp_libname=g++
2392         ;;
2393 esac
2394 if test "$GXX" = yes; then
2395         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2396         cf_save="$LIBS"
2397         CF_ADD_LIB($cf_gpp_libname)
2398         AC_TRY_LINK([
2399 #include <$cf_gpp_libname/builtin.h>
2400         ],
2401         [two_arg_error_handler_t foo2 = lib_error_handler],
2402         [cf_cxx_library=yes
2403          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2404          if test "$cf_gpp_libname" = cpp ; then
2405             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2406          else
2407             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2408          fi],
2409         [AC_TRY_LINK([
2410 #include <builtin.h>
2411         ],
2412         [two_arg_error_handler_t foo2 = lib_error_handler],
2413         [cf_cxx_library=yes
2414          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2415          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2416         [cf_cxx_library=no])])
2417         LIBS="$cf_save"
2418         AC_MSG_RESULT($cf_cxx_library)
2419 fi
2420 ])dnl
2421 dnl ---------------------------------------------------------------------------
2422 dnl CF_GXX_VERSION version: 7 updated: 2012/06/16 14:55:39
2423 dnl --------------
2424 dnl Check for version of g++
2425 AC_DEFUN([CF_GXX_VERSION],[
2426 AC_REQUIRE([AC_PROG_CPP])
2427 GXX_VERSION=none
2428 if test "$GXX" = yes; then
2429         AC_MSG_CHECKING(version of ${CXX:-g++})
2430         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2431         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2432         AC_MSG_RESULT($GXX_VERSION)
2433 fi
2434 ])dnl
2435 dnl ---------------------------------------------------------------------------
2436 dnl CF_GXX_WARNINGS version: 7 updated: 2012/06/16 14:55:39
2437 dnl ---------------
2438 dnl Check if the compiler supports useful warning options.
2439 dnl
2440 dnl Most of gcc's options apply to g++, except:
2441 dnl     -Wbad-function-cast
2442 dnl     -Wmissing-declarations
2443 dnl     -Wnested-externs
2444 dnl
2445 dnl Omit a few (for now):
2446 dnl     -Winline
2447 dnl
2448 dnl Parameter:
2449 dnl     $1 is an optional list of g++ warning flags that a particular
2450 dnl             application might want to use, e.g., "no-unused" for
2451 dnl             -Wno-unused
2452 dnl Special:
2453 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2454 dnl
2455 AC_DEFUN([CF_GXX_WARNINGS],
2456 [
2457
2458 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2459 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2460
2461 AC_REQUIRE([CF_GXX_VERSION])
2462
2463 AC_LANG_SAVE
2464 AC_LANG_CPLUSPLUS
2465
2466 cat > conftest.$ac_ext <<EOF
2467 #line __oline__ "configure"
2468 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2469 EOF
2470
2471 if test "$INTEL_CPLUSPLUS" = yes
2472 then
2473 # The "-wdXXX" options suppress warnings:
2474 # remark #1419: external declaration in primary source file
2475 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2476 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2477 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2478 # remark #193: zero used for undefined preprocessing identifier
2479 # remark #593: variable "curs_sb_left_arrow" was set but never used
2480 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2481 # remark #869: parameter "tw" was never referenced
2482 # remark #981: operands are evaluated in unspecified order
2483 # warning #269: invalid format string conversion
2484
2485         AC_CHECKING([for $CC warning options])
2486         cf_save_CXXFLAGS="$CXXFLAGS"
2487         EXTRA_CXXFLAGS="-Wall"
2488         for cf_opt in \
2489                 wd1419 \
2490                 wd1682 \
2491                 wd1683 \
2492                 wd1684 \
2493                 wd193 \
2494                 wd279 \
2495                 wd593 \
2496                 wd810 \
2497                 wd869 \
2498                 wd981
2499         do
2500                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2501                 if AC_TRY_EVAL(ac_compile); then
2502                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2503                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2504                 fi
2505         done
2506         CXXFLAGS="$cf_save_CXXFLAGS"
2507
2508 elif test "$GXX" = yes
2509 then
2510         AC_CHECKING([for $CXX warning options])
2511         cf_save_CXXFLAGS="$CXXFLAGS"
2512         EXTRA_CXXFLAGS="-W -Wall"
2513         cf_gxx_extra_warnings=""
2514         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2515         case "$GCC_VERSION" in
2516         [[1-2]].*)
2517                 ;;
2518         *)
2519                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2520                 ;;
2521         esac
2522         for cf_opt in \
2523                 Wabi \
2524                 fabi-version=0 \
2525                 Woverloaded-virtual \
2526                 Wsign-promo \
2527                 Wsynth \
2528                 Wold-style-cast \
2529                 Wcast-align \
2530                 Wcast-qual \
2531                 Wmissing-prototypes \
2532                 Wpointer-arith \
2533                 Wshadow \
2534                 Wstrict-prototypes \
2535                 Wundef $cf_gxx_extra_warnings $1
2536         do
2537                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2538                 if AC_TRY_EVAL(ac_compile); then
2539                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2540                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2541                 else
2542                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2543                 fi
2544         done
2545         CXXFLAGS="$cf_save_CXXFLAGS"
2546 fi
2547
2548 rm -rf conftest*
2549 AC_LANG_RESTORE
2550 AC_SUBST(EXTRA_CXXFLAGS)
2551 ])dnl
2552 dnl ---------------------------------------------------------------------------
2553 dnl CF_HASHED_DB version: 4 updated: 2010/05/29 16:31:02
2554 dnl ------------
2555 dnl Look for an instance of the Berkeley hashed database.
2556 dnl
2557 dnl $1 = optional parameter, to specify install-prefix for the database.
2558 AC_DEFUN([CF_HASHED_DB],
2559 [
2560 ifelse([$1],,,[
2561 case $1 in #(vi
2562 yes|*able*) #(vi
2563     ;;
2564 *)
2565     if test -d "$1" ; then
2566         CF_ADD_INCDIR($1/include)
2567         CF_ADD_LIBDIR($1/lib)
2568     fi
2569 esac
2570 ])
2571 AC_CHECK_HEADER(db.h,[
2572 CF_HASHED_DB_VERSION
2573 if test "$cf_cv_hashed_db_version" = unknown ; then
2574         AC_MSG_ERROR(Cannot determine version of db)
2575 else
2576         CF_HASHED_DB_LIBS
2577         if test "$cf_cv_hashed_db_libs" = unknown ; then
2578                 AC_MSG_ERROR(Cannot determine library for db)
2579         elif test "$cf_cv_hashed_db_libs" != default ; then
2580                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2581         fi
2582 fi
2583 ],[
2584         AC_MSG_ERROR(Cannot find db.h)
2585 ])
2586 ])dnl
2587 dnl ---------------------------------------------------------------------------
2588 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2589 dnl -----------------
2590 dnl Given that we have the header and version for hashed database, find the
2591 dnl library information.
2592 AC_DEFUN([CF_HASHED_DB_LIBS],
2593 [
2594 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2595 cf_cv_hashed_db_libs=unknown
2596 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2597 do
2598         cf_save_libs="$LIBS"
2599         if test -n "$cf_db_libs"; then
2600                 CF_ADD_LIB($cf_db_libs)
2601         fi
2602         CF_MSG_LOG(checking for library "$cf_db_libs")
2603         AC_TRY_LINK([
2604 $ac_includes_default
2605 #include <db.h>
2606 ],[
2607         char *path = "/tmp/foo";
2608 #ifdef DB_VERSION_MAJOR
2609 #if DB_VERSION_MAJOR >= 4
2610         DB *result = 0;
2611         db_create(&result, NULL, 0);
2612         result->open(result,
2613                 NULL,
2614                 path,
2615                 path,
2616                 DB_HASH,
2617                 DB_CREATE,
2618                 0644);
2619 #elif DB_VERSION_MAJOR >= 3
2620         DB *result = 0;
2621         db_create(&result, NULL, 0);
2622         result->open(result,
2623                 path,
2624                 path,
2625                 DB_HASH,
2626                 DB_CREATE,
2627                 0644);
2628 #elif DB_VERSION_MAJOR >= 2
2629         DB *result = 0;
2630         db_open(path,
2631                 DB_HASH,
2632                 DB_CREATE,
2633                 0644,
2634                 (DB_ENV *) 0,
2635                 (DB_INFO *) 0,
2636                 &result);
2637 #endif /* DB_VERSION_MAJOR */
2638 #else
2639         DB *result = dbopen(path,
2640                      2,
2641                      0644,
2642                      DB_HASH,
2643                      0);
2644 #endif
2645         ${cf_cv_main_return:-return}(result != 0)
2646 ],[
2647         if test -n "$cf_db_libs" ; then
2648                 cf_cv_hashed_db_libs=$cf_db_libs
2649         else
2650                 cf_cv_hashed_db_libs=default
2651         fi
2652         LIBS="$cf_save_libs"
2653         break
2654 ])
2655         LIBS="$cf_save_libs"
2656 done
2657 ])
2658 ])dnl
2659 dnl ---------------------------------------------------------------------------
2660 dnl CF_HASHED_DB_VERSION version: 3 updated: 2007/12/01 15:01:37
2661 dnl --------------------
2662 dnl Given that we have the header file for hashed database, find the version
2663 dnl information.
2664 AC_DEFUN([CF_HASHED_DB_VERSION],
2665 [
2666 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2667 cf_cv_hashed_db_version=unknown
2668
2669 for cf_db_version in 1 2 3 4 5
2670 do
2671         CF_MSG_LOG(checking for db version $cf_db_version)
2672         AC_TRY_COMPILE([
2673 $ac_includes_default
2674 #include <db.h>
2675
2676 #ifdef DB_VERSION_MAJOR
2677         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2678 #if $cf_db_version == DB_VERSION_MAJOR
2679         /* ok */
2680 #else
2681         make an error
2682 #endif
2683 #else
2684 #if $cf_db_version == 1
2685         /* ok: assuming this is DB 1.8.5 */
2686 #else
2687         make an error
2688 #endif
2689 #endif
2690 ],[DBT *foo = 0],[
2691         cf_cv_hashed_db_version=$cf_db_version
2692         break
2693         ])
2694 done
2695 ])
2696 ])dnl
2697 dnl ---------------------------------------------------------------------------
2698 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
2699 dnl --------------
2700 dnl Construct a search-list of directories for a nonstandard header-file
2701 dnl
2702 dnl Parameters
2703 dnl     $1 = the variable to return as result
2704 dnl     $2 = the package name
2705 AC_DEFUN([CF_HEADER_PATH],
2706 [
2707 $1=
2708
2709 # collect the current set of include-directories from compiler flags
2710 cf_header_path_list=""
2711 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2712         for cf_header_path in $CPPFLAGS $CFLAGS
2713         do
2714                 case $cf_header_path in #(vi
2715                 -I*)
2716                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2717                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2718                         cf_header_path_list="$cf_header_path_list [$]$1"
2719                         ;;
2720                 esac
2721         done
2722 fi
2723
2724 # add the variations for the package we are looking for
2725 CF_SUBDIR_PATH($1,$2,include)
2726
2727 test "$includedir" != NONE && \
2728 test "$includedir" != "/usr/include" && \
2729 test -d "$includedir" && {
2730         test -d $includedir &&    $1="[$]$1 $includedir"
2731         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2732 }
2733
2734 test "$oldincludedir" != NONE && \
2735 test "$oldincludedir" != "/usr/include" && \
2736 test -d "$oldincludedir" && {
2737         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2738         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2739 }
2740
2741 $1="[$]$1 $cf_header_path_list"
2742 ])dnl
2743 dnl ---------------------------------------------------------------------------
2744 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2745 dnl ---------------
2746 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2747 AC_DEFUN([CF_HELP_MESSAGE],
2748 [AC_DIVERT_HELP([$1])dnl
2749 ])dnl
2750 dnl ---------------------------------------------------------------------------
2751 dnl CF_INCLUDE_DIRS version: 7 updated: 2012/11/10 19:15:05
2752 dnl ---------------
2753 dnl Construct the list of include-options according to whether we're building
2754 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
2755 dnl with gcc, don't append the includedir if it happens to be /usr/include,
2756 dnl since that usually breaks gcc's shadow-includes.
2757 AC_DEFUN([CF_INCLUDE_DIRS],
2758 [
2759 if test "$GCC" != yes; then
2760         CPPFLAGS="-I\${includedir} $CPPFLAGS"
2761 elif test "$includedir" != "/usr/include"; then
2762         if test "$includedir" = '${prefix}/include' ; then
2763                 if test $prefix != /usr ; then
2764                         CPPFLAGS="-I\${includedir} $CPPFLAGS"
2765                 fi
2766         else
2767                 CPPFLAGS="-I\${includedir} $CPPFLAGS"
2768         fi
2769 fi
2770 if test "$srcdir" != "."; then
2771         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
2772 fi
2773 CPPFLAGS="-I. -I../include $CPPFLAGS"
2774 AC_SUBST(CPPFLAGS)
2775 ])dnl
2776 dnl ---------------------------------------------------------------------------
2777 dnl CF_INTEL_COMPILER version: 5 updated: 2013/02/10 10:41:05
2778 dnl -----------------
2779 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2780 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2781 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2782 dnl
2783 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2784 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2785 dnl the wrappers for gcc and g++ warnings.
2786 dnl
2787 dnl $1 = GCC (default) or GXX
2788 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2789 dnl $3 = CFLAGS (default) or CXXFLAGS
2790 AC_DEFUN([CF_INTEL_COMPILER],[
2791 AC_REQUIRE([AC_CANONICAL_HOST])
2792 ifelse([$2],,INTEL_COMPILER,[$2])=no
2793
2794 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2795         case $host_os in
2796         linux*|gnu*)
2797                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2798                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2799                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2800                 AC_TRY_COMPILE([],[
2801 #ifdef __INTEL_COMPILER
2802 #else
2803 make an error
2804 #endif
2805 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2806 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
2807 ],[])
2808                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2809                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2810                 ;;
2811         esac
2812 fi
2813 ])dnl
2814 dnl ---------------------------------------------------------------------------
2815 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
2816 dnl ----------
2817 dnl Check if we have either a function or macro for 'isascii()'.
2818 AC_DEFUN([CF_ISASCII],
2819 [
2820 AC_MSG_CHECKING(for isascii)
2821 AC_CACHE_VAL(cf_cv_have_isascii,[
2822         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2823         [cf_cv_have_isascii=yes],
2824         [cf_cv_have_isascii=no])
2825 ])dnl
2826 AC_MSG_RESULT($cf_cv_have_isascii)
2827 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
2828 ])dnl
2829 dnl ---------------------------------------------------------------------------
2830 dnl CF_LARGEFILE version: 8 updated: 2012/10/06 08:57:51
2831 dnl ------------
2832 dnl Add checks for large file support.
2833 AC_DEFUN([CF_LARGEFILE],[
2834 ifdef([AC_FUNC_FSEEKO],[
2835     AC_SYS_LARGEFILE
2836     if test "$enable_largefile" != no ; then
2837         AC_FUNC_FSEEKO
2838
2839         # Normally we would collect these definitions in the config.h,
2840         # but (like _XOPEN_SOURCE), some environments rely on having these
2841         # defined before any of the system headers are included.  Another
2842         # case comes up with C++, e.g., on AIX the compiler compiles the
2843         # header files by themselves before looking at the body files it is
2844         # told to compile.  For ncurses, those header files do not include
2845         # the config.h
2846         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2847         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2848         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2849
2850         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2851                 AC_TRY_COMPILE([
2852 #include <sys/types.h>
2853 #include <dirent.h>
2854                 ],[
2855                 /* if transitional largefile support is setup, this is true */
2856                 extern struct dirent64 * readdir(DIR *);
2857                 struct dirent64 *x = readdir((DIR *)0);
2858                 struct dirent *y = readdir((DIR *)0);
2859                 int z = x - y;
2860                 ],
2861                 [cf_cv_struct_dirent64=yes],
2862                 [cf_cv_struct_dirent64=no])
2863         ])
2864         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
2865     fi
2866 ])
2867 ])
2868 dnl ---------------------------------------------------------------------------
2869 dnl CF_LDFLAGS_STATIC version: 10 updated: 2011/09/24 12:51:48
2870 dnl -----------------
2871 dnl Check for compiler/linker flags used to temporarily force usage of static
2872 dnl libraries.  This depends on the compiler and platform.  Use this to help
2873 dnl ensure that the linker picks up a given library based on its position in
2874 dnl the list of linker options and libraries.
2875 AC_DEFUN([CF_LDFLAGS_STATIC],[
2876
2877 if test "$GCC" = yes ; then
2878         case $cf_cv_system_name in #(
2879         OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)         #( vi
2880                 LDFLAGS_STATIC=
2881                 LDFLAGS_SHARED=
2882                 ;;
2883     *)  #( normally, except when broken
2884         LDFLAGS_STATIC=-static
2885         LDFLAGS_SHARED=-dynamic
2886         ;;
2887     esac
2888 else
2889         case $cf_cv_system_name in #(
2890         aix[[4-7]]*)    #( from ld manpage
2891                 LDFLAGS_STATIC=-bstatic
2892                 LDFLAGS_SHARED=-bdynamic
2893                 ;;
2894         hpux*)          #( from ld manpage for hpux10.20, hpux11.11
2895                 # We could also use just "archive" and "shared".
2896                 LDFLAGS_STATIC=-Wl,-a,archive_shared
2897                 LDFLAGS_SHARED=-Wl,-a,shared_archive
2898                 ;;
2899         irix*)          #( from ld manpage IRIX64
2900                 LDFLAGS_STATIC=-Bstatic
2901                 LDFLAGS_SHARED=-Bdynamic
2902                 ;;
2903         osf[[45]]*)     #( from ld manpage osf4.0d, osf5.1
2904                 # alternative "-oldstyle_liblookup" (not in cc manpage)
2905                 LDFLAGS_STATIC=-noso
2906                 LDFLAGS_SHARED=-so_archive
2907                 ;;
2908         solaris2*)
2909                 LDFLAGS_STATIC=-Bstatic
2910                 LDFLAGS_SHARED=-Bdynamic
2911                 ;;
2912         esac
2913 fi
2914
2915 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
2916 then
2917         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
2918
2919         rm -f libconftest.a
2920         cat >conftest.$ac_ext <<EOF
2921 #line __oline__ "configure"
2922 #include <stdio.h>
2923 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
2924 EOF
2925         if AC_TRY_EVAL(ac_compile) ; then
2926                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
2927                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
2928         fi
2929         rm -f conftest.*
2930
2931         cf_save_LIBS="$LIBS"
2932
2933         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
2934         AC_TRY_LINK([
2935 #line __oline__ "configure"
2936 #include <stdio.h>
2937 int cf_ldflags_static(FILE *fp);
2938 ],[
2939         return cf_ldflags_static(stdin);
2940 ],[
2941         # some linkers simply ignore the -dynamic
2942         case x`file conftest$ac_exeext 2>/dev/null` in #(vi
2943         *static*) # (vi
2944                 cf_ldflags_static=no
2945                 ;;
2946         *)
2947                 cf_ldflags_static=yes
2948                 ;;
2949         esac
2950 ],[cf_ldflags_static=no])
2951
2952         rm -f libconftest.*
2953         LIBS="$cf_save_LIBS"
2954
2955         AC_MSG_RESULT($cf_ldflags_static)
2956
2957         if test $cf_ldflags_static != yes
2958         then
2959                 LDFLAGS_STATIC=
2960                 LDFLAGS_SHARED=
2961         fi
2962 else
2963         LDFLAGS_STATIC=
2964         LDFLAGS_SHARED=
2965 fi
2966
2967 AC_SUBST(LDFLAGS_STATIC)
2968 AC_SUBST(LDFLAGS_SHARED)
2969 ])
2970 dnl ---------------------------------------------------------------------------
2971 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
2972 dnl ---------------
2973 dnl For the given system and compiler, find the compiler flags to pass to the
2974 dnl loader to use the "rpath" feature.
2975 AC_DEFUN([CF_LD_RPATH_OPT],
2976 [
2977 AC_REQUIRE([CF_CHECK_CACHE])
2978
2979 LD_RPATH_OPT=
2980 AC_MSG_CHECKING(for an rpath option)
2981 case $cf_cv_system_name in #(vi
2982 irix*) #(vi
2983         if test "$GCC" = yes; then
2984                 LD_RPATH_OPT="-Wl,-rpath,"
2985         else
2986                 LD_RPATH_OPT="-rpath "
2987         fi
2988         ;;
2989 linux*|gnu*|k*bsd*-gnu) #(vi
2990         LD_RPATH_OPT="-Wl,-rpath,"
2991         ;;
2992 openbsd[[2-9]].*|mirbsd*) #(vi
2993         LD_RPATH_OPT="-Wl,-rpath,"
2994         ;;
2995 dragonfly*|freebsd*) #(vi
2996         LD_RPATH_OPT="-rpath "
2997         ;;
2998 netbsd*) #(vi
2999         LD_RPATH_OPT="-Wl,-rpath,"
3000         ;;
3001 osf*|mls+*) #(vi
3002         LD_RPATH_OPT="-rpath "
3003         ;;
3004 solaris2*) #(vi
3005         LD_RPATH_OPT="-R"
3006         ;;
3007 *)
3008         ;;
3009 esac
3010 AC_MSG_RESULT($LD_RPATH_OPT)
3011
3012 case "x$LD_RPATH_OPT" in #(vi
3013 x-R*)
3014         AC_MSG_CHECKING(if we need a space after rpath option)
3015         cf_save_LIBS="$LIBS"
3016         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3017         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3018         LIBS="$cf_save_LIBS"
3019         AC_MSG_RESULT($cf_rpath_space)
3020         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3021         ;;
3022 esac
3023 ])dnl
3024 dnl ---------------------------------------------------------------------------
3025 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
3026 dnl ---------------
3027 dnl Construct a search-list of directories for a nonstandard library-file
3028 dnl
3029 dnl Parameters
3030 dnl     $1 = the variable to return as result
3031 dnl     $2 = the package name
3032 AC_DEFUN([CF_LIBRARY_PATH],
3033 [
3034 $1=
3035 cf_library_path_list=""
3036 if test -n "${LDFLAGS}${LIBS}" ; then
3037         for cf_library_path in $LDFLAGS $LIBS
3038         do
3039                 case $cf_library_path in #(vi
3040                 -L*)
3041                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3042                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3043                         cf_library_path_list="$cf_library_path_list [$]$1"
3044                         ;;
3045                 esac
3046         done
3047 fi
3048
3049 CF_SUBDIR_PATH($1,$2,lib)
3050
3051 $1="$cf_library_path_list [$]$1"
3052 ])dnl
3053 dnl ---------------------------------------------------------------------------
3054 dnl CF_LIB_PREFIX version: 9 updated: 2012/01/21 19:28:10
3055 dnl -------------
3056 dnl Compute the library-prefix for the given host system
3057 dnl $1 = variable to set
3058 define([CF_LIB_PREFIX],
3059 [
3060         case $cf_cv_system_name in #(vi
3061         OS/2*|os2*) #(vi
3062         LIB_PREFIX=''
3063         ;;
3064         *)      LIB_PREFIX='lib'
3065         ;;
3066         esac
3067 ifelse($1,,,[$1=$LIB_PREFIX])
3068         AC_SUBST(LIB_PREFIX)
3069 ])dnl
3070 dnl ---------------------------------------------------------------------------
3071 dnl CF_LIB_RULES version: 69 updated: 2013/03/09 19:22:30
3072 dnl ------------
3073 dnl Append definitions and rules for the given models to the subdirectory
3074 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3075 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3076 dnl the corresponding makefile to list the models that we'll generate.
3077 dnl
3078 dnl For shared libraries, make a list of symbolic links to construct when
3079 dnl generating each library.  The convention used for Linux is the simplest
3080 dnl one:
3081 dnl     lib<name>.so    ->
3082 dnl     lib<name>.so.<major>    ->
3083 dnl     lib<name>.so.<maj>.<minor>
3084 dnl
3085 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3086 AC_DEFUN([CF_LIB_RULES],
3087 [
3088 cf_prefix=$LIB_PREFIX
3089 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3090
3091 case $cf_cv_shlib_version in #(vi
3092 cygdll|mingw)
3093         TINFO_NAME=$TINFO_ARG_SUFFIX
3094         TINFO_SUFFIX=.dll
3095         ;;
3096 esac
3097
3098 if test -n "$TINFO_SUFFIX" ; then
3099         case $TINFO_SUFFIX in
3100         tw*)
3101                 TINFO_NAME="${TINFO_NAME}tw"
3102                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw//'`
3103                 ;;
3104         t*)
3105                 TINFO_NAME="${TINFO_NAME}t"
3106                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t//'`
3107                 ;;
3108         w*)
3109                 TINFO_NAME="${TINFO_NAME}w"
3110                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w//'`
3111                 ;;
3112         esac
3113 fi
3114
3115 for cf_dir in $SRC_SUBDIRS
3116 do
3117         if test ! -d $srcdir/$cf_dir ; then
3118                 continue
3119         elif test -f $srcdir/$cf_dir/modules; then
3120
3121                 SHARED_LIB=
3122                 Libs_To_Make=
3123                 for cf_item in $cf_LIST_MODELS
3124                 do
3125                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3126                         cf_libname=$cf_dir
3127                         test "$cf_dir" = c++ && cf_libname=ncurses++
3128                         if test $cf_item = shared ; then
3129                         if test "$cf_cv_do_symlinks" = yes ; then
3130                                 case "$cf_cv_shlib_version" in #(vi
3131                                 rel) #(vi
3132                                         case "$cf_cv_system_name" in #(vi
3133                                         darwin*)
3134                                         case .${LIB_SUFFIX} in
3135                                         .tw*)
3136                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3137                                                 cf_suffix=tw'.${REL_VERSION}'"$cf_suffix"
3138                                                 ;;
3139                                         .t*)
3140                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3141                                                 cf_suffix=t'.${REL_VERSION}'"$cf_suffix"
3142                                                 ;;
3143                                         .w*)
3144                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3145                                                 cf_suffix=w'.${REL_VERSION}'"$cf_suffix"
3146                                                 ;;
3147                                         *)
3148                                                 cf_suffix='.${REL_VERSION}'"$cf_suffix"
3149                                                 ;;
3150                                         esac
3151                                         ;; #(vi
3152                                         *) cf_suffix="$cf_suffix"'.${REL_VERSION}' ;;
3153                                         esac
3154                                         ;;
3155                                 abi)
3156                                         case "$cf_cv_system_name" in #(vi
3157                                         darwin*)
3158                                         case .${LIB_SUFFIX} in
3159                                         .tw*)
3160                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3161                                                 cf_suffix=tw'.${ABI_VERSION}'"$cf_suffix"
3162                                                 ;;
3163                                         .t*)
3164                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3165                                                 cf_suffix=t'.${ABI_VERSION}'"$cf_suffix"
3166                                                 ;;
3167                                         .w*)
3168                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3169                                                 cf_suffix=w'.${ABI_VERSION}'"$cf_suffix"
3170                                                 ;;
3171                                         *)
3172                                                 cf_suffix='.${ABI_VERSION}'"$cf_suffix"
3173                                                 ;;
3174                                         esac
3175                                         ;; #(vi
3176                                         *) cf_suffix="$cf_suffix"'.${ABI_VERSION}' ;;
3177                                         esac
3178                                         ;;
3179                                 esac
3180                         fi
3181                         # cygwin needs import library, and has unique naming convention
3182                         # use autodetected ${cf_prefix} for import lib and static lib, but
3183                         # use 'cyg' prefix for shared lib.
3184                         case $cf_cv_shlib_version in #(vi
3185                         cygdll) #(vi
3186                                 cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3187                                 Libs_To_Make="$Libs_To_Make ../lib/cyg${cf_libname}${cf_cygsuf}"
3188                                 continue
3189                                 ;;
3190                         mingw)
3191                                 cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3192                                 Libs_To_Make="$Libs_To_Make ../lib/lib${cf_libname}${cf_cygsuf}"
3193                                 continue
3194                                 ;;
3195                         esac
3196                         fi
3197                         Libs_To_Make="$Libs_To_Make ../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3198                 done
3199
3200                 if test $cf_dir = ncurses ; then
3201                         cf_subsets="$LIB_SUBSETS"
3202                         cf_r_parts="$cf_subsets"
3203                         cf_liblist="$Libs_To_Make"
3204
3205                         while test -n "$cf_r_parts"
3206                         do
3207                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3208                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3209                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3210                                         cf_item=
3211                                         case $cf_l_parts in #(vi
3212                                         *termlib*) #(vi
3213                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3214                                                 ;;
3215                                         *ticlib*)
3216                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3217                                                 ;;
3218                                         *)
3219                                                 break
3220                                                 ;;
3221                                         esac
3222                                         if test -n "$cf_item"; then
3223                                                 Libs_To_Make="$cf_item $Libs_To_Make"
3224                                         fi
3225                                 else
3226                                         break
3227                                 fi
3228                         done
3229                 else
3230                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3231                 fi
3232
3233                 if test $cf_dir = c++; then
3234                         if test "x$with_shared_cxx" != xyes; then
3235                                 cf_list=
3236                                 for cf_item in $Libs_To_Make
3237                                 do
3238                                         case $cf_item in
3239                                         *.a)
3240                                                 ;;
3241                                         *)
3242                                                 cf_item=`echo "$cf_item" | sed -e 's/\.so.*/.a/'`
3243                                                 ;;
3244                                         esac
3245                                         for cf_test in $cf_list
3246                                         do
3247                                                 if test "$cf_test" = "$cf_item"
3248                                                 then
3249                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3250                                                         cf_item=
3251                                                         break
3252                                                 fi
3253                                         done
3254                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3255                                 done
3256                                 Libs_To_Make="$cf_list"
3257                         fi
3258                 fi
3259
3260                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3261                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3262                         $cf_dir/Makefile >$cf_dir/Makefile.out
3263                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3264
3265                 $AWK -f $srcdir/mk-0th.awk \
3266                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3267                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3268
3269                 for cf_subset in $cf_subsets
3270                 do
3271                         cf_subdirs=
3272                         for cf_item in $cf_LIST_MODELS
3273                         do
3274
3275                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3276                         CF_UPPER(cf_ITEM,$cf_item)
3277
3278                         CXX_MODEL=$cf_ITEM
3279                         if test "$CXX_MODEL" = SHARED; then
3280                                 case $cf_cv_shlib_version in #(vi
3281                                 cygdll|mingw) #(vi
3282                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3283                                         with_shared_cxx=yes
3284                                         ;;
3285                                 *)
3286                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3287                                         ;;
3288                                 esac
3289                         fi
3290
3291                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3292                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3293
3294                         # Test for case where we build libtinfo with a different name.
3295                         cf_libname=$cf_dir
3296                         if test $cf_dir = ncurses ; then
3297                                 case $cf_subset in
3298                                 *base*)
3299                                         cf_libname=${cf_libname}$LIB_SUFFIX
3300                                         ;;
3301                                 *termlib*)
3302                                         cf_libname=$TINFO_LIB_SUFFIX
3303                                         ;;
3304                                 ticlib*)
3305                                         cf_libname=$TICS_LIB_SUFFIX
3306                                         ;;
3307                                 esac
3308                         elif test $cf_dir = c++ ; then
3309                                 cf_libname=ncurses++$LIB_SUFFIX
3310                         else
3311                                 cf_libname=${cf_libname}$LIB_SUFFIX
3312                         fi
3313                         if test -n "${DFT_ARG_SUFFIX}" ; then
3314                                 # undo $LIB_SUFFIX add-on in CF_LIB_SUFFIX
3315                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${LIB_SUFFIX}%%"`
3316                         fi
3317
3318                         # These dependencies really are for development, not
3319                         # builds, but they are useful in porting, too.
3320                         cf_depend="../include/ncurses_cfg.h"
3321                         if test "$srcdir" = "."; then
3322                                 cf_reldir="."
3323                         else
3324                                 cf_reldir="\${srcdir}"
3325                         fi
3326
3327                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3328                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3329                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3330                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3331                         fi
3332
3333                         cf_dir_suffix=
3334                         old_cf_suffix="$cf_suffix"
3335                         if test "$cf_cv_shlib_version_infix" = yes ; then
3336                         if test -n "$LIB_SUFFIX" ; then
3337                                 case $LIB_SUFFIX in
3338                                 tw*)
3339                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
3340                                         cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3341                                         cf_dir_suffix=tw
3342                                         ;;
3343                                 t*)
3344                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
3345                                         cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3346                                         cf_dir_suffix=t
3347                                         ;;
3348                                 w*)
3349                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
3350                                         cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3351                                         cf_dir_suffix=w
3352                                         ;;
3353                                 esac
3354                         fi
3355                         fi
3356
3357                         $AWK -f $srcdir/mk-1st.awk \
3358                                 name=${cf_libname}${cf_dir_suffix} \
3359                                 traces=$LIB_TRACING \
3360                                 MODEL=$cf_ITEM \
3361                                 CXX_MODEL=$CXX_MODEL \
3362                                 model=$cf_subdir \
3363                                 prefix=$cf_prefix \
3364                                 suffix=$cf_suffix \
3365                                 subset=$cf_subset \
3366                                 driver=$cf_cv_term_driver \
3367                                 SymLink="$LN_S" \
3368                                 TermlibRoot=$TINFO_NAME \
3369                                 TermlibSuffix=$TINFO_SUFFIX \
3370                                 ShlibVer=$cf_cv_shlib_version \
3371                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3372                                 ReLink=${cf_cv_do_relink:-no} \
3373                                 DoLinks=$cf_cv_do_symlinks \
3374                                 rmSoLocs=$cf_cv_rm_so_locs \
3375                                 ldconfig="$LDCONFIG" \
3376                                 overwrite=$WITH_OVERWRITE \
3377                                 depend="$cf_depend" \
3378                                 host="$host" \
3379                                 libtool_version="$LIBTOOL_VERSION" \
3380                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3381
3382                         cf_suffix="$old_cf_suffix"
3383
3384                         for cf_subdir2 in $cf_subdirs lib
3385                         do
3386                                 test $cf_subdir = $cf_subdir2 && break
3387                         done
3388                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3389                         $AWK -f $srcdir/mk-2nd.awk \
3390                                 name=$cf_dir \
3391                                 traces=$LIB_TRACING \
3392                                 MODEL=$cf_ITEM \
3393                                 model=$cf_subdir \
3394                                 subset=$cf_subset \
3395                                 srcdir=$srcdir \
3396                                 echo=$WITH_ECHO \
3397                                 crenames=$cf_cv_prog_CC_c_o \
3398                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3399                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3400                         cf_subdirs="$cf_subdirs $cf_subdir"
3401                         done
3402                 done
3403         fi
3404
3405         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
3406 done
3407
3408 for cf_dir in $SRC_SUBDIRS
3409 do
3410         if test ! -d $srcdir/$cf_dir ; then
3411                 continue
3412         fi
3413
3414         if test -f $cf_dir/Makefile ; then
3415                 case "$cf_dir" in
3416                 Ada95) #(vi
3417                         echo 'libs \' >> Makefile
3418                         echo 'install.libs \' >> Makefile
3419                         echo 'uninstall.libs ::' >> Makefile
3420                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
3421                         ;;
3422                 esac
3423         fi
3424
3425         if test -f $srcdir/$cf_dir/modules; then
3426                 echo >> Makefile
3427                 if test -f $srcdir/$cf_dir/headers; then
3428 cat >> Makefile <<CF_EOF
3429 install.includes \\
3430 uninstall.includes \\
3431 CF_EOF
3432                 fi
3433 if test "$cf_dir" != "c++" ; then
3434 echo 'lint \' >> Makefile
3435 fi
3436 cat >> Makefile <<CF_EOF
3437 libs \\
3438 lintlib \\
3439 install.libs \\
3440 uninstall.libs \\
3441 install.$cf_dir \\
3442 uninstall.$cf_dir ::
3443         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3444 CF_EOF
3445         elif test -f $srcdir/$cf_dir/headers; then
3446 cat >> Makefile <<CF_EOF
3447
3448 libs \\
3449 install.libs \\
3450 uninstall.libs \\
3451 install.includes \\
3452 uninstall.includes ::
3453         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3454 CF_EOF
3455 fi
3456 done
3457
3458 cat >> Makefile <<CF_EOF
3459
3460 install.libs uninstall.libs \\
3461 install.data uninstall.data ::
3462 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3463 CF_EOF
3464
3465 if test "x$cf_with_manpages" = xyes; then
3466 cat >> Makefile <<CF_EOF
3467
3468 install.man \\
3469 uninstall.man ::
3470         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
3471 CF_EOF
3472 fi
3473
3474 cat >> Makefile <<CF_EOF
3475
3476 distclean ::
3477         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3478         rm -f headers.sh headers.sed mk_shared_lib.sh
3479         rm -f edit_man.* man_alias.*
3480         rm -rf \${DIRS_TO_MAKE}
3481 CF_EOF
3482
3483 # Special case: tack's manpage lives in its own directory.
3484 if test "x$cf_with_manpages" = xyes; then
3485 if test -d tack ; then
3486 if test -f $srcdir/$tack.h; then
3487 cat >> Makefile <<CF_EOF
3488
3489 install.man \\
3490 uninstall.man ::
3491         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
3492 CF_EOF
3493 fi
3494 fi
3495 fi
3496
3497 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3498 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3499 dnl anything, and will make it more standardized.  It's awkward to decide this
3500 dnl at configuration because of quoting, so we'll simply make all headers
3501 dnl installed via a script that can do the right thing.
3502
3503 rm -f headers.sed headers.sh
3504
3505 dnl ( generating this script makes the makefiles a little tidier :-)
3506 echo creating headers.sh
3507 cat >headers.sh <<CF_EOF
3508 #! /bin/sh
3509 # This shell script is generated by the 'configure' script.  It is invoked in a
3510 # subdirectory of the build tree.  It generates a sed-script in the parent
3511 # directory that is used to adjust includes for header files that reside in a
3512 # subdirectory of /usr/include, etc.
3513 PRG=""
3514 while test \[$]# != 3
3515 do
3516 PRG="\$PRG \[$]1"; shift
3517 done
3518 DST=\[$]1
3519 REF=\[$]2
3520 SRC=\[$]3
3521 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3522 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3523 echo installing \$SRC in \$DST
3524 CF_EOF
3525
3526 if test $WITH_CURSES_H = yes; then
3527         cat >>headers.sh <<CF_EOF
3528 case \$DST in
3529 /*/include/*)
3530         END=\`basename \$DST\`
3531         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3532         do
3533                 NAME=\`basename \$i\`
3534                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3535         done
3536         ;;
3537 *)
3538         echo "" >> \$TMPSED
3539         ;;
3540 esac
3541 CF_EOF
3542
3543 else
3544         cat >>headers.sh <<CF_EOF
3545 case \$DST in
3546 /*/include/*)
3547         END=\`basename \$DST\`
3548         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3549         do
3550                 NAME=\`basename \$i\`
3551                 if test "\$NAME" = "curses.h"
3552                 then
3553                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3554                         NAME=ncurses.h
3555                 fi
3556                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3557         done
3558         ;;
3559 *)
3560         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3561         ;;
3562 esac
3563 CF_EOF
3564 fi
3565 cat >>headers.sh <<CF_EOF
3566 rm -f \$TMPSRC
3567 sed -f \$TMPSED \$SRC > \$TMPSRC
3568 NAME=\`basename \$SRC\`
3569 CF_EOF
3570 if test $WITH_CURSES_H != yes; then
3571         cat >>headers.sh <<CF_EOF
3572 test "\$NAME" = "curses.h" && NAME=ncurses.h
3573 CF_EOF
3574 fi
3575 cat >>headers.sh <<CF_EOF
3576 # Just in case someone gzip'd manpages, remove the conflicting copy.
3577 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3578
3579 eval \$PRG \$TMPSRC \$DST/\$NAME
3580 rm -f \$TMPSRC \$TMPSED
3581 CF_EOF
3582
3583 chmod 0755 headers.sh
3584
3585 for cf_dir in $SRC_SUBDIRS
3586 do
3587         if test ! -d $srcdir/$cf_dir ; then
3588                 continue
3589         fi
3590
3591         if test -f $srcdir/$cf_dir/headers; then
3592                 $AWK -f $srcdir/mk-hdr.awk \
3593                         subset="$LIB_SUBSETS" \
3594                         compat="$WITH_CURSES_H" \
3595                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3596         fi
3597
3598         if test -f $srcdir/$cf_dir/modules; then
3599                 if test "$cf_dir" != "c++" ; then
3600                         cat >>$cf_dir/Makefile <<"CF_EOF"
3601 depend : ${AUTO_SRC}
3602         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3603
3604 # DO NOT DELETE THIS LINE -- make depend depends on it.
3605 CF_EOF
3606                 fi
3607         fi
3608 done
3609 AC_SUBST(Libs_To_Make)
3610 ])dnl
3611 dnl ---------------------------------------------------------------------------
3612 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3613 dnl -------------
3614 dnl Find the and soname for the given shared library.  Set the cache variable
3615 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3616 dnl variable to "unknown".
3617 dnl
3618 dnl $1 = headers
3619 dnl $2 = code
3620 dnl $3 = library name
3621 AC_DEFUN([CF_LIB_SONAME],
3622 [
3623 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3624
3625 cf_cv_$3_soname=unknown
3626 if test "$cross_compiling" != yes ; then
3627 cat >conftest.$ac_ext <<CF_EOF
3628 $1
3629 int main()
3630 {
3631 $2
3632         ${cf_cv_main_return:-return}(0);
3633 }
3634 CF_EOF
3635 cf_save_LIBS="$LIBS"
3636         CF_ADD_LIB($3)
3637         if AC_TRY_EVAL(ac_compile) ; then
3638                 if AC_TRY_EVAL(ac_link) ; then
3639                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3640                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3641                 fi
3642         fi
3643 rm -rf conftest*
3644 LIBS="$cf_save_LIBS"
3645 fi
3646 ])
3647 ])
3648 dnl ---------------------------------------------------------------------------
3649 dnl CF_LIB_SUFFIX version: 18 updated: 2012/02/25 15:20:07
3650 dnl -------------
3651 dnl Compute the library file-suffix from the given model name
3652 dnl $1 = model name
3653 dnl $2 = variable to set (the nominal library suffix)
3654 dnl $3 = dependency variable to set (actual filename)
3655 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3656 AC_DEFUN([CF_LIB_SUFFIX],
3657 [
3658         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3659         case $1 in #(vi
3660         libtool) #(vi
3661                 $2='.la'
3662                 $3=[$]$2
3663                 ;;
3664         normal) #(vi
3665                 $2='.a'
3666                 $3=[$]$2
3667                 ;;
3668         debug) #(vi
3669                 $2='_g.a'
3670                 $3=[$]$2
3671                 ;;
3672         profile) #(vi
3673                 $2='_p.a'
3674                 $3=[$]$2
3675                 ;;
3676         shared) #(vi
3677                 case $cf_cv_system_name in
3678                 aix[[5-7]]*) #(vi
3679                         $2='.a'
3680                         $3=[$]$2
3681                         ;;
3682                 cygwin*|mingw*) #(vi
3683                         $2='.dll'
3684                         $3='.dll.a'
3685                         ;;
3686                 darwin*) #(vi
3687                         $2='.dylib'
3688                         $3=[$]$2
3689                         ;;
3690                 hpux*) #(vi
3691                         case $target in
3692                         ia64*) #(vi
3693                                 $2='.so'
3694                                 $3=[$]$2
3695                                 ;;
3696                         *) #(vi
3697                                 $2='.sl'
3698                                 $3=[$]$2
3699                                 ;;
3700                         esac
3701                         ;;
3702                 *)      $2='.so'
3703                         $3=[$]$2
3704                         ;;
3705                 esac
3706         esac
3707         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3708         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
3709 ])dnl
3710 dnl ---------------------------------------------------------------------------
3711 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
3712 dnl -----------
3713 dnl Compute the string to append to -library from the given model name
3714 dnl $1 = model name
3715 dnl $2 = variable to set
3716 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3717 AC_DEFUN([CF_LIB_TYPE],
3718 [
3719         case $1 in
3720         libtool) $2=''   ;;
3721         normal)  $2=''   ;;
3722         debug)   $2='_g' ;;
3723         profile) $2='_p' ;;
3724         shared)  $2=''   ;;
3725         esac
3726         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3727 ])dnl
3728 dnl ---------------------------------------------------------------------------
3729 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
3730 dnl ----------------
3731 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3732 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3733 dnl have to provide wrappers for global tables to ensure they're linked
3734 dnl properly.
3735 AC_DEFUN([CF_LINK_DATAONLY],
3736 [
3737 AC_MSG_CHECKING([if data-only library module links])
3738 AC_CACHE_VAL(cf_cv_link_dataonly,[
3739         rm -f conftest.a
3740         cat >conftest.$ac_ext <<EOF
3741 #line __oline__ "configure"
3742 int     testdata[[3]] = { 123, 456, 789 };
3743 EOF
3744         if AC_TRY_EVAL(ac_compile) ; then
3745                 mv conftest.o data.o && \
3746                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3747         fi
3748         rm -f conftest.$ac_ext data.o
3749         cat >conftest.$ac_ext <<EOF
3750 #line __oline__ "configure"
3751 int     testfunc()
3752 {
3753 #if defined(NeXT)
3754         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3755 #else
3756         extern int testdata[[3]];
3757         return testdata[[0]] == 123
3758            &&  testdata[[1]] == 456
3759            &&  testdata[[2]] == 789;
3760 #endif
3761 }
3762 EOF
3763         if AC_TRY_EVAL(ac_compile); then
3764                 mv conftest.o func.o && \
3765                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3766         fi
3767         rm -f conftest.$ac_ext func.o
3768         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3769         cf_saveLIBS="$LIBS"
3770         LIBS="conftest.a $LIBS"
3771         AC_TRY_RUN([
3772         int main()
3773         {
3774                 extern int testfunc();
3775                 ${cf_cv_main_return:-return} (!testfunc());
3776         }
3777         ],
3778         [cf_cv_link_dataonly=yes],
3779         [cf_cv_link_dataonly=no],
3780         [cf_cv_link_dataonly=unknown])
3781         LIBS="$cf_saveLIBS"
3782         ])
3783 AC_MSG_RESULT($cf_cv_link_dataonly)
3784
3785 if test "$cf_cv_link_dataonly" = no ; then
3786         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
3787         BROKEN_LINKER=1
3788 fi
3789
3790 ])dnl
3791 dnl ---------------------------------------------------------------------------
3792 dnl CF_LINK_FUNCS version: 8 updated: 2012/10/06 17:56:13
3793 dnl -------------
3794 dnl Most Unix systems have both link and symlink, a few don't have symlink.
3795 dnl A few non-Unix systems implement symlink, but not link.
3796 dnl A few non-systems implement neither (or have nonfunctional versions).
3797 AC_DEFUN([CF_LINK_FUNCS],
3798 [
3799 AC_CHECK_FUNCS( \
3800         remove \
3801         unlink )
3802
3803 if test "$cross_compiling" = yes ; then
3804         AC_CHECK_FUNCS( \
3805                 link \
3806                 symlink )
3807 else
3808         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
3809                 cf_cv_link_funcs=
3810                 for cf_func in link symlink ; do
3811                         AC_TRY_RUN([
3812 #include <sys/types.h>
3813 #include <sys/stat.h>
3814 #ifdef HAVE_UNISTD_H
3815 #include <unistd.h>
3816 #endif
3817 int main()
3818 {
3819         int fail = 0;
3820         char *src = "config.log";
3821         char *dst = "conftest.chk";
3822         struct stat src_sb;
3823         struct stat dst_sb;
3824
3825         stat(src, &src_sb);
3826         fail = ($cf_func("config.log", "conftest.chk") < 0)
3827             || (stat(dst, &dst_sb) < 0)
3828             || (dst_sb.st_mtime != src_sb.st_mtime);
3829 #ifdef HAVE_UNLINK
3830         unlink(dst);
3831 #else
3832         remove(dst);
3833 #endif
3834         ${cf_cv_main_return:-return} (fail);
3835 }
3836                         ],[
3837                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
3838                         eval 'ac_cv_func_'$cf_func'=yes'],[
3839                         eval 'ac_cv_func_'$cf_func'=no'],[
3840                         eval 'ac_cv_func_'$cf_func'=error'])
3841                 done
3842                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
3843         ])
3844         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
3845         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
3846 fi
3847 ])dnl
3848 dnl ---------------------------------------------------------------------------
3849 dnl CF_MAKEFLAGS version: 14 updated: 2011/03/31 19:29:46
3850 dnl ------------
3851 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
3852 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
3853 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
3854 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
3855 AC_DEFUN([CF_MAKEFLAGS],
3856 [
3857 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
3858         cf_cv_makeflags=''
3859         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
3860         do
3861                 cat >cf_makeflags.tmp <<CF_EOF
3862 SHELL = /bin/sh
3863 all :
3864         @ echo '.$cf_option'
3865 CF_EOF
3866                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
3867                 case "$cf_result" in
3868                 .*k)
3869                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
3870                         case "$cf_result" in
3871                         .*CC=*) cf_cv_makeflags=
3872                                 ;;
3873                         *)      cf_cv_makeflags=$cf_option
3874                                 ;;
3875                         esac
3876                         break
3877                         ;;
3878                 .-)     ;;
3879                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
3880                         ;;
3881                 esac
3882         done
3883         rm -f cf_makeflags.tmp
3884 ])
3885
3886 AC_SUBST(cf_cv_makeflags)
3887 ])dnl
3888 dnl ---------------------------------------------------------------------------
3889 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
3890 dnl ------------
3891 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
3892 dnl a monocase filesystem.
3893 AC_DEFUN([CF_MAKE_TAGS],[
3894 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
3895
3896 AC_CHECK_PROGS(CTAGS, exctags ctags)
3897 AC_CHECK_PROGS(ETAGS, exetags etags)
3898
3899 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
3900
3901 if test "$cf_cv_mixedcase" = yes ; then
3902         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
3903 else
3904         MAKE_UPPER_TAGS=no
3905 fi
3906
3907 if test "$MAKE_UPPER_TAGS" = yes ; then
3908         MAKE_UPPER_TAGS=
3909 else
3910         MAKE_UPPER_TAGS="#"
3911 fi
3912
3913 if test "$MAKE_LOWER_TAGS" = yes ; then
3914         MAKE_LOWER_TAGS=
3915 else
3916         MAKE_LOWER_TAGS="#"
3917 fi
3918
3919 AC_SUBST(CTAGS)
3920 AC_SUBST(ETAGS)
3921
3922 AC_SUBST(MAKE_UPPER_TAGS)
3923 AC_SUBST(MAKE_LOWER_TAGS)
3924 ])dnl
3925 dnl ---------------------------------------------------------------------------
3926 dnl CF_MANPAGE_FORMAT version: 9 updated: 2010/10/23 16:10:30
3927 dnl -----------------
3928 dnl Option to allow user to override automatic configuration of manpage format.
3929 dnl There are several special cases:
3930 dnl
3931 dnl     gzip - man checks for, can display gzip'd files
3932 dnl     compress - man checks for, can display compressed files
3933 dnl     BSDI - files in the cat-directories are suffixed ".0"
3934 dnl     formatted - installer should format (put files in cat-directory)
3935 dnl     catonly - installer should only format, e.g., for a turnkey system.
3936 dnl
3937 dnl There are other configurations which this macro does not test, e.g., HPUX's
3938 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
3939 dnl convention would not match our use).
3940 AC_DEFUN([CF_MANPAGE_FORMAT],
3941 [
3942 AC_REQUIRE([CF_PATHSEP])
3943 AC_MSG_CHECKING(format of man-pages)
3944
3945 AC_ARG_WITH(manpage-format,
3946         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
3947                           optionally formatted/catonly, e.g., gzip,formatted],
3948         [MANPAGE_FORMAT=$withval],
3949         [MANPAGE_FORMAT=unknown])
3950
3951 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
3952 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
3953
3954 cf_unknown=
3955
3956 case $MANPAGE_FORMAT in
3957 unknown)
3958   if test -z "$MANPATH" ; then
3959     MANPATH="/usr/man:/usr/share/man"
3960   fi
3961
3962   # look for the 'date' man-page (it's most likely to be installed!)
3963   MANPAGE_FORMAT=
3964   cf_preform=no
3965   cf_catonly=yes
3966   cf_example=date
3967
3968   IFS="${IFS:-  }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
3969   for cf_dir in $MANPATH; do
3970     test -z "$cf_dir" && cf_dir=/usr/man
3971     for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
3972     do
3973       cf_test=`echo $cf_name | sed -e 's/*//'`
3974       if test "x$cf_test" = "x$cf_name" ; then
3975
3976         case "$cf_name" in
3977         *.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
3978         *.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
3979         *.0)    MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
3980         *)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
3981         esac
3982
3983         case "$cf_name" in
3984         $cf_dir/man*)
3985           cf_catonly=no
3986           ;;
3987         $cf_dir/cat*)
3988           cf_preform=yes
3989           ;;
3990         esac
3991         break
3992       fi
3993
3994       # if we found a match in either man* or cat*, stop looking
3995       if test -n "$MANPAGE_FORMAT" ; then
3996         cf_found=no
3997         test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
3998         test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
3999         case "$cf_name" in
4000         $cf_dir/cat*)
4001           cf_found=yes
4002           ;;
4003         esac
4004         test $cf_found=yes && break
4005       fi
4006     done
4007     # only check the first directory in $MANPATH where we find manpages
4008     if test -n "$MANPAGE_FORMAT" ; then
4009        break
4010     fi
4011   done
4012   # if we did not find the example, just assume it is normal
4013   test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
4014   IFS="$ac_save_ifs"
4015   ;;
4016 *)
4017   for cf_option in $MANPAGE_FORMAT; do
4018      case $cf_option in #(vi
4019      gzip|compress|BSDI|normal|formatted|catonly)
4020        ;;
4021      *)
4022        cf_unknown="$cf_unknown $cf_option"
4023        ;;
4024      esac
4025   done
4026   ;;
4027 esac
4028
4029 AC_MSG_RESULT($MANPAGE_FORMAT)
4030 if test -n "$cf_unknown" ; then
4031   AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
4032 fi
4033 ])dnl
4034 dnl ---------------------------------------------------------------------------
4035 dnl CF_MANPAGE_RENAMES version: 7 updated: 2005/06/18 18:51:57
4036 dnl ------------------
4037 dnl The Debian people have their own naming convention for manpages.  This
4038 dnl option lets us override the name of the file containing renaming, or
4039 dnl disable it altogether.
4040 AC_DEFUN([CF_MANPAGE_RENAMES],
4041 [
4042 AC_MSG_CHECKING(for manpage renaming)
4043
4044 AC_ARG_WITH(manpage-renames,
4045         [  --with-manpage-renames  specify manpage-renaming],
4046         [MANPAGE_RENAMES=$withval],
4047         [MANPAGE_RENAMES=yes])
4048
4049 case ".$MANPAGE_RENAMES" in #(vi
4050 .no) #(vi
4051   ;;
4052 .|.yes)
4053   # Debian 'man' program?
4054   if test -f /etc/debian_version ; then
4055     MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
4056   else
4057     MANPAGE_RENAMES=no
4058   fi
4059   ;;
4060 esac
4061
4062 if test "$MANPAGE_RENAMES" != no ; then
4063   if test -f $srcdir/man/$MANPAGE_RENAMES ; then
4064     MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
4065   elif test ! -f $MANPAGE_RENAMES ; then
4066     AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
4067   fi
4068
4069   test ! -d man && mkdir man
4070
4071   # Construct a sed-script to perform renaming within man-pages
4072   if test -n "$MANPAGE_RENAMES" ; then
4073     test ! -d man && mkdir man
4074     sh $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
4075   fi
4076 fi
4077
4078 AC_MSG_RESULT($MANPAGE_RENAMES)
4079 AC_SUBST(MANPAGE_RENAMES)
4080 ])dnl
4081 dnl ---------------------------------------------------------------------------
4082 dnl CF_MANPAGE_SYMLINKS version: 5 updated: 2010/07/24 17:12:40
4083 dnl -------------------
4084 dnl Some people expect each tool to make all aliases for manpages in the
4085 dnl man-directory.  This accommodates the older, less-capable implementations
4086 dnl of 'man', and is optional.
4087 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4088 [
4089 AC_MSG_CHECKING(if manpage aliases will be installed)
4090
4091 AC_ARG_WITH(manpage-aliases,
4092         [  --with-manpage-aliases  specify manpage-aliases using .so],
4093         [MANPAGE_ALIASES=$withval],
4094         [MANPAGE_ALIASES=yes])
4095
4096 AC_MSG_RESULT($MANPAGE_ALIASES)
4097
4098 case "x$LN_S" in #(vi
4099 xln*) #(vi
4100         cf_use_symlinks=yes
4101         ;;
4102 *)
4103         cf_use_symlinks=no
4104         ;;
4105 esac
4106
4107 MANPAGE_SYMLINKS=no
4108 if test "$MANPAGE_ALIASES" = yes ; then
4109 AC_MSG_CHECKING(if manpage symlinks should be used)
4110
4111 AC_ARG_WITH(manpage-symlinks,
4112         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
4113         [MANPAGE_SYMLINKS=$withval],
4114         [MANPAGE_SYMLINKS=$cf_use_symlinks])
4115
4116 if test "$$cf_use_symlinks" = no; then
4117 if test "$MANPAGE_SYMLINKS" = yes ; then
4118         AC_MSG_WARN(cannot make symlinks, will use .so files)
4119         MANPAGE_SYMLINKS=no
4120 fi
4121 fi
4122
4123 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4124 fi
4125
4126 ])dnl
4127 dnl ---------------------------------------------------------------------------
4128 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4129 dnl --------------
4130 dnl This option causes manpages to be run through tbl(1) to generate tables
4131 dnl correctly.
4132 AC_DEFUN([CF_MANPAGE_TBL],
4133 [
4134 AC_MSG_CHECKING(for manpage tbl)
4135
4136 AC_ARG_WITH(manpage-tbl,
4137         [  --with-manpage-tbl      specify manpage processing with tbl],
4138         [MANPAGE_TBL=$withval],
4139         [MANPAGE_TBL=no])
4140
4141 AC_MSG_RESULT($MANPAGE_TBL)
4142 ])dnl
4143 dnl ---------------------------------------------------------------------------
4144 dnl CF_MAN_PAGES version: 43 updated: 2013/02/09 12:53:45
4145 dnl ------------
4146 dnl Try to determine if the man-pages on the system are compressed, and if
4147 dnl so, what format is used.  Use this information to construct a script that
4148 dnl will install man-pages.
4149 AC_DEFUN([CF_MAN_PAGES],
4150 [
4151 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4152 CF_MANPAGE_FORMAT
4153 CF_MANPAGE_RENAMES
4154 CF_MANPAGE_SYMLINKS
4155 CF_MANPAGE_TBL
4156
4157   if test "$prefix" = "NONE" ; then
4158      cf_prefix="$ac_default_prefix"
4159   else
4160      cf_prefix="$prefix"
4161   fi
4162
4163   case "$MANPAGE_FORMAT" in # (vi
4164   *catonly*) # (vi
4165     cf_format=yes
4166     cf_inboth=no
4167     ;;
4168   *formatted*) # (vi
4169     cf_format=yes
4170     cf_inboth=yes
4171     ;;
4172   *)
4173     cf_format=no
4174     cf_inboth=no
4175     ;;
4176   esac
4177
4178 test ! -d man && mkdir man
4179
4180 cf_so_strip=
4181 cf_compress=
4182 case "$MANPAGE_FORMAT" in #(vi
4183 *compress*) #(vi
4184         cf_so_strip="Z"
4185         cf_compress=compress
4186   ;;
4187 *gzip*)
4188         cf_so_strip="gz"
4189         cf_compress=gzip
4190   ;;
4191 esac
4192
4193 cf_edit_man=./edit_man.sh
4194 cf_man_alias=`pwd`/man_alias.sed
4195
4196 cat >$cf_edit_man <<CF_EOF
4197 #! /bin/sh
4198 # this script is generated by the configure-script CF_MAN_PAGES macro.
4199
4200 prefix="$cf_prefix"
4201 datarootdir="$datarootdir"
4202 datadir="$datadir"
4203
4204 NCURSES_MAJOR="$NCURSES_MAJOR"
4205 NCURSES_MINOR="$NCURSES_MINOR"
4206 NCURSES_PATCH="$NCURSES_PATCH"
4207
4208 NCURSES_OSPEED="$NCURSES_OSPEED"
4209 TERMINFO="$TERMINFO"
4210
4211 INSTALL="$INSTALL"
4212 INSTALL_DATA="$INSTALL_DATA"
4213
4214 transform="$program_transform_name"
4215
4216 TMP=\${TMPDIR:=/tmp}/man\$\$
4217 trap "rm -f \$TMP" 0 1 2 5 15
4218
4219 form=\[$]1
4220 shift || exit 1
4221
4222 verb=\[$]1
4223 shift || exit 1
4224
4225 mandir=\[$]1
4226 shift || exit 1
4227
4228 srcdir=\[$]1
4229 top_srcdir=\[$]srcdir/..
4230 shift || exit 1
4231
4232 if test "\$form" = normal ; then
4233         if test "$cf_format" = yes ; then
4234         if test "$cf_inboth" = no ; then
4235                 sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4236                 exit $?
4237         fi
4238         fi
4239         cf_subdir=\$mandir/man
4240         cf_tables=$MANPAGE_TBL
4241 else
4242         cf_subdir=\$mandir/cat
4243         cf_tables=yes
4244 fi
4245
4246 # process the list of source-files
4247 for i in \[$]* ; do
4248 case \$i in #(vi
4249 *.orig|*.rej) ;; #(vi
4250 *.[[0-9]]*)
4251         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4252         if test \$verb = installing ; then
4253         if test ! -d \$cf_subdir\${section} ; then
4254                 mkdir -p \$cf_subdir\$section
4255         fi
4256         fi
4257
4258         # replace variables in man page
4259         if test ! -f $cf_man_alias ; then
4260 cat >>$cf_man_alias <<-CF_EOF2
4261                 s,@DATADIR@,\$datadir,g
4262                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
4263                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
4264                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
4265                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
4266                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
4267                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
4268 CF_EOF
4269         ifelse($1,,,[
4270         for cf_name in $1
4271         do
4272                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4273                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4274 cat >>$cf_edit_man <<-CF_EOF
4275                 s,@$cf_NAME@,$cf_name,g
4276 CF_EOF
4277         done
4278         ])
4279 cat >>$cf_edit_man <<CF_EOF
4280 CF_EOF2
4281                 echo "...made $cf_man_alias"
4282         fi
4283
4284         aliases=
4285         cf_source=\`basename \$i\`
4286         inalias=\$cf_source
4287         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4288         if test ! -f \$inalias ; then
4289                 echo .. skipped \$cf_source
4290                 continue
4291         fi
4292 CF_EOF
4293
4294 if test "$MANPAGE_ALIASES" != no ; then
4295 cat >>$cf_edit_man <<CF_EOF
4296         nCurses=ignore.3x
4297         test $with_curses_h = yes && nCurses=ncurses.3x
4298         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4299 CF_EOF
4300 fi
4301
4302 if test "$MANPAGE_RENAMES" = no ; then
4303 cat >>$cf_edit_man <<CF_EOF
4304         # perform program transformations for section 1 man pages
4305         if test \$section = 1 ; then
4306                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4307         else
4308                 cf_target=\$cf_subdir\${section}/\$cf_source
4309         fi
4310 CF_EOF
4311 else
4312 cat >>$cf_edit_man <<CF_EOF
4313         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4314         if test -z "\$cf_target" ; then
4315                 echo '? missing rename for '\$cf_source
4316                 cf_target="\$cf_source"
4317         fi
4318         cf_target="\$cf_subdir\${section}/\${cf_target}"
4319
4320 CF_EOF
4321 fi
4322
4323 cat >>$cf_edit_man <<CF_EOF
4324         sed     -f $cf_man_alias \\
4325 CF_EOF
4326
4327 if test -f $MANPAGE_RENAMES ; then
4328 cat >>$cf_edit_man <<CF_EOF
4329                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4330 CF_EOF
4331 else
4332 cat >>$cf_edit_man <<CF_EOF
4333                 < \$i >\$TMP
4334 CF_EOF
4335 fi
4336
4337 cat >>$cf_edit_man <<CF_EOF
4338 if test \$cf_tables = yes ; then
4339         tbl \$TMP >\$TMP.out
4340         mv \$TMP.out \$TMP
4341 fi
4342 CF_EOF
4343
4344 if test $with_overwrite != yes ; then
4345 cat >>$cf_edit_man <<CF_EOF
4346         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
4347         mv \$TMP.out \$TMP
4348 CF_EOF
4349 fi
4350
4351 if test $with_curses_h != yes ; then
4352 cat >>$cf_edit_man <<CF_EOF
4353         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4354         mv \$TMP.out \$TMP
4355 CF_EOF
4356 fi
4357
4358 cat >>$cf_edit_man <<CF_EOF
4359         if test \$form = format ; then
4360                 nroff -man \$TMP >\$TMP.out
4361                 mv \$TMP.out \$TMP
4362         fi
4363 CF_EOF
4364
4365 if test -n "$cf_compress" ; then
4366 cat >>$cf_edit_man <<CF_EOF
4367         if test \$verb = installing ; then
4368         if ( $cf_compress -f \$TMP )
4369         then
4370                 mv \$TMP.$cf_so_strip \$TMP
4371         fi
4372         fi
4373         cf_target="\$cf_target.$cf_so_strip"
4374 CF_EOF
4375 fi
4376
4377 case "$MANPAGE_FORMAT" in #(vi
4378 *BSDI*)
4379 cat >>$cf_edit_man <<CF_EOF
4380         if test \$form = format ; then
4381                 # BSDI installs only .0 suffixes in the cat directories
4382                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
4383         fi
4384 CF_EOF
4385   ;;
4386 esac
4387
4388 cat >>$cf_edit_man <<CF_EOF
4389         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
4390         if test \$verb = installing ; then
4391                 echo \$verb \$cf_target
4392                 \$INSTALL_DATA \$TMP \$cf_target
4393                 test -d \$cf_subdir\${section} &&
4394                 test -n "\$aliases" && (
4395                         cd \$cf_subdir\${section} && (
4396                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
4397                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
4398                                 cf_target=\`basename \$cf_target\`
4399                                 for cf_alias in \$aliases
4400                                 do
4401                                         if test \$section = 1 ; then
4402                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4403                                         fi
4404
4405                                         if test "$MANPAGE_SYMLINKS" = yes ; then
4406                                                 if test -f \$cf_alias\${suffix} ; then
4407                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
4408                                                         then
4409                                                                 continue
4410                                                         fi
4411                                                 fi
4412                                                 echo .. \$verb alias \$cf_alias\${suffix}
4413 CF_EOF
4414 case "x$LN_S" in #(vi
4415 *-f) #(vi
4416 cat >>$cf_edit_man <<CF_EOF
4417                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4418 CF_EOF
4419         ;;
4420 *)
4421 cat >>$cf_edit_man <<CF_EOF
4422                                                 rm -f \$cf_alias\${suffix}
4423                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4424 CF_EOF
4425         ;;
4426 esac
4427 cat >>$cf_edit_man <<CF_EOF
4428                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
4429                                                 echo ".so \$cf_source" >\$TMP
4430 CF_EOF
4431 if test -n "$cf_compress" ; then
4432 cat >>$cf_edit_man <<CF_EOF
4433                                                 if test -n "$cf_so_strip" ; then
4434                                                         $cf_compress -f \$TMP
4435                                                         mv \$TMP.$cf_so_strip \$TMP
4436                                                 fi
4437 CF_EOF
4438 fi
4439 cat >>$cf_edit_man <<CF_EOF
4440                                                 echo .. \$verb alias \$cf_alias\${suffix}
4441                                                 rm -f \$cf_alias\${suffix}
4442                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
4443                                         fi
4444                                 done
4445                         )
4446                 )
4447         elif test \$verb = removing ; then
4448                 test -f \$cf_target && (
4449                         echo \$verb \$cf_target
4450                         rm -f \$cf_target
4451                 )
4452                 test -d \$cf_subdir\${section} &&
4453                 test -n "\$aliases" && (
4454                         cd \$cf_subdir\${section} && (
4455                                 for cf_alias in \$aliases
4456                                 do
4457                                         if test \$section = 1 ; then
4458                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4459                                         fi
4460
4461                                         echo .. \$verb alias \$cf_alias\${suffix}
4462                                         rm -f \$cf_alias\${suffix}
4463                                 done
4464                         )
4465                 )
4466         else
4467 #               echo ".hy 0"
4468                 cat \$TMP
4469         fi
4470         ;;
4471 esac
4472 done
4473
4474 if test $cf_inboth = yes ; then
4475 if test \$form != format ; then
4476         sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4477 fi
4478 fi
4479
4480 exit 0
4481 CF_EOF
4482 chmod 755 $cf_edit_man
4483
4484 ])dnl
4485 dnl ---------------------------------------------------------------------------
4486 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
4487 dnl -----------
4488 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
4489 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
4490 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
4491 AC_DEFUN([CF_MATH_LIB],
4492 [
4493 AC_CACHE_CHECK(if -lm needed for math functions,
4494         cf_cv_need_libm,[
4495         AC_TRY_LINK([
4496         #include <stdio.h>
4497         #include <math.h>
4498         ],
4499         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
4500         [cf_cv_need_libm=no],
4501         [cf_cv_need_libm=yes])])
4502 if test "$cf_cv_need_libm" = yes
4503 then
4504 ifelse($1,,[
4505         CF_ADD_LIB(m)
4506 ],[$1=-lm])
4507 fi
4508 ])
4509 dnl ---------------------------------------------------------------------------
4510 dnl CF_MIXEDCASE_FILENAMES version: 4 updated: 2012/10/02 20:55:03
4511 dnl ----------------------
4512 dnl Check if the file-system supports mixed-case filenames.  If we're able to
4513 dnl create a lowercase name and see it as uppercase, it doesn't support that.
4514 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
4515 [
4516 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
4517 if test "$cross_compiling" = yes ; then
4518         case $target_alias in #(vi
4519         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-mingw32*|*-uwin*) #(vi
4520                 cf_cv_mixedcase=no
4521                 ;;
4522         *)
4523                 cf_cv_mixedcase=yes
4524                 ;;
4525         esac
4526 else
4527         rm -f conftest CONFTEST
4528         echo test >conftest
4529         if test -f CONFTEST ; then
4530                 cf_cv_mixedcase=no
4531         else
4532                 cf_cv_mixedcase=yes
4533         fi
4534         rm -f conftest CONFTEST
4535 fi
4536 ])
4537 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
4538 ])dnl
4539 dnl ---------------------------------------------------------------------------
4540 dnl CF_MKSTEMP version: 9 updated: 2012/10/03 04:34:49
4541 dnl ----------
4542 dnl Check for a working mkstemp.  This creates two files, checks that they are
4543 dnl successfully created and distinct (AmigaOS apparently fails on the last).
4544 AC_DEFUN([CF_MKSTEMP],[
4545 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
4546 rm -rf conftest*
4547 AC_TRY_RUN([
4548 #include <sys/types.h>
4549 #include <stdlib.h>
4550 #include <stdio.h>
4551 #include <string.h>
4552 #include <sys/stat.h>
4553 int main()
4554 {
4555         char *tmpl = "conftestXXXXXX";
4556         char name[2][80];
4557         int n;
4558         int result = 0;
4559         int fd;
4560         struct stat sb;
4561
4562         umask(077);
4563         for (n = 0; n < 2; ++n) {
4564                 strcpy(name[n], tmpl);
4565                 if ((fd = mkstemp(name[n])) >= 0) {
4566                         if (!strcmp(name[n], tmpl)
4567                          || stat(name[n], &sb) != 0
4568                          || (sb.st_mode & S_IFMT) != S_IFREG
4569                          || (sb.st_mode & 077) != 0) {
4570                                 result = 1;
4571                         }
4572                         close(fd);
4573                 }
4574         }
4575         if (result == 0
4576          && !strcmp(name[0], name[1]))
4577                 result = 1;
4578         ${cf_cv_main_return:-return}(result);
4579 }
4580 ],[cf_cv_func_mkstemp=yes
4581 ],[cf_cv_func_mkstemp=no
4582 ],[cf_cv_func_mkstemp=maybe])
4583 ])
4584 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
4585         AC_CHECK_FUNC(mkstemp)
4586 fi
4587 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
4588         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
4589 fi
4590 ])dnl
4591 dnl ---------------------------------------------------------------------------
4592 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
4593 dnl ----------
4594 dnl Write a debug message to config.log, along with the line number in the
4595 dnl configure script.
4596 AC_DEFUN([CF_MSG_LOG],[
4597 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
4598 ])dnl
4599 dnl ---------------------------------------------------------------------------
4600 dnl CF_NCURSES_ABI_6 version: 1 updated: 2005/09/17 18:42:49
4601 dnl ----------------
4602 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
4603 dnl warn about this.
4604 AC_DEFUN([CF_NCURSES_ABI_6],[
4605 if test "${with_abi_version+set}" != set; then
4606         case $cf_cv_rel_version in
4607         5.*)
4608                 cf_cv_rel_version=6.0
4609                 cf_cv_abi_version=6
4610                 AC_MSG_WARN(Overriding ABI version to $cf_cv_abi_version)
4611                 ;;
4612         esac
4613 fi
4614 ])dnl
4615 dnl ---------------------------------------------------------------------------
4616 dnl CF_NO_LEAKS_OPTION version: 5 updated: 2012/10/02 20:55:03
4617 dnl ------------------
4618 dnl see CF_WITH_NO_LEAKS
4619 AC_DEFUN([CF_NO_LEAKS_OPTION],[
4620 AC_MSG_CHECKING(if you want to use $1 for testing)
4621 AC_ARG_WITH($1,
4622         [$2],
4623         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
4624          $4
4625 ])
4626         : ${with_cflags:=-g}
4627         : ${with_no_leaks:=yes}
4628          with_$1=yes],
4629         [with_$1=])
4630 AC_MSG_RESULT(${with_$1:-no})
4631
4632 case .$with_cflags in #(vi
4633 .*-g*)
4634         case .$CFLAGS in #(vi
4635         .*-g*) #(vi
4636                 ;;
4637         *)
4638                 CF_ADD_CFLAGS([-g])
4639                 ;;
4640         esac
4641         ;;
4642 esac
4643 ])dnl
4644 dnl ---------------------------------------------------------------------------
4645 dnl CF_NUMBER_SYNTAX version: 1 updated: 2003/09/20 18:12:49
4646 dnl ----------------
4647 dnl Check if the given variable is a number.  If not, report an error.
4648 dnl $1 is the variable
4649 dnl $2 is the message
4650 AC_DEFUN([CF_NUMBER_SYNTAX],[
4651 if test -n "$1" ; then
4652   case $1 in #(vi
4653   [[0-9]]*) #(vi
4654         ;;
4655   *)
4656         AC_MSG_ERROR($2 is not a number: $1)
4657         ;;
4658   esac
4659 else
4660   AC_MSG_ERROR($2 value is empty)
4661 fi
4662 ])dnl
4663 dnl ---------------------------------------------------------------------------
4664 dnl CF_OBJ_SUBDIR version: 4 updated: 2002/02/23 20:38:31
4665 dnl -------------
4666 dnl Compute the object-directory name from the given model name
4667 AC_DEFUN([CF_OBJ_SUBDIR],
4668 [
4669         case $1 in
4670         libtool) $2='obj_lo'  ;;
4671         normal)  $2='objects' ;;
4672         debug)   $2='obj_g' ;;
4673         profile) $2='obj_p' ;;
4674         shared)
4675                 case $cf_cv_system_name in #(vi
4676                 cygwin) #(vi
4677                         $2='objects' ;;
4678                 *)
4679                         $2='obj_s' ;;
4680                 esac
4681         esac
4682 ])dnl
4683 dnl ---------------------------------------------------------------------------
4684 dnl CF_PATHSEP version: 6 updated: 2012/09/29 18:38:12
4685 dnl ----------
4686 dnl Provide a value for the $PATH and similar separator (or amend the value
4687 dnl as provided in autoconf 2.5x).
4688 AC_DEFUN([CF_PATHSEP],
4689 [
4690         AC_MSG_CHECKING(for PATH separator)
4691         case $cf_cv_system_name in
4692         os2*)   PATH_SEPARATOR=';'  ;;
4693         *)      ${PATH_SEPARATOR:=':'}  ;;
4694         esac
4695 ifelse([$1],,,[$1=$PATH_SEPARATOR])
4696         AC_SUBST(PATH_SEPARATOR)
4697         AC_MSG_RESULT($PATH_SEPARATOR)
4698 ])dnl
4699 dnl ---------------------------------------------------------------------------
4700 dnl CF_PATH_SYNTAX version: 14 updated: 2012/06/19 20:58:54
4701 dnl --------------
4702 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
4703 dnl begins with one of the prefix/exec_prefix variables, and then again if the
4704 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
4705 dnl delayed evaluation of those symbols.
4706 AC_DEFUN([CF_PATH_SYNTAX],[
4707 if test "x$prefix" != xNONE; then
4708   cf_path_syntax="$prefix"
4709 else
4710   cf_path_syntax="$ac_default_prefix"
4711 fi
4712
4713 case ".[$]$1" in #(vi
4714 .\[$]\(*\)*|.\'*\'*) #(vi
4715   ;;
4716 ..|./*|.\\*) #(vi
4717   ;;
4718 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
4719   ;;
4720 .\[$]{*prefix}*|.\[$]{*dir}*) #(vi
4721   eval $1="[$]$1"
4722   case ".[$]$1" in #(vi
4723   .NONE/*)
4724     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4725     ;;
4726   esac
4727   ;; #(vi
4728 .no|.NONE/*)
4729   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4730   ;;
4731 *)
4732   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
4733   ;;
4734 esac
4735 ])dnl
4736 dnl ---------------------------------------------------------------------------
4737 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
4738 dnl -------------
4739 dnl Check for the package-config program, unless disabled by command-line.
4740 AC_DEFUN([CF_PKG_CONFIG],
4741 [
4742 AC_MSG_CHECKING(if you want to use pkg-config)
4743 AC_ARG_WITH(pkg-config,
4744         [  --with-pkg-config{=path} enable/disable use of pkg-config],
4745         [cf_pkg_config=$withval],
4746         [cf_pkg_config=yes])
4747 AC_MSG_RESULT($cf_pkg_config)
4748
4749 case $cf_pkg_config in #(vi
4750 no) #(vi
4751         PKG_CONFIG=none
4752         ;;
4753 yes) #(vi
4754         CF_ACVERSION_CHECK(2.52,
4755                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
4756                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
4757         ;;
4758 *)
4759         PKG_CONFIG=$withval
4760         ;;
4761 esac
4762
4763 test -z "$PKG_CONFIG" && PKG_CONFIG=none
4764 if test "$PKG_CONFIG" != none ; then
4765         CF_PATH_SYNTAX(PKG_CONFIG)
4766 fi
4767
4768 AC_SUBST(PKG_CONFIG)
4769 ])dnl
4770 dnl ---------------------------------------------------------------------------
4771 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
4772 dnl -----------------
4773 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
4774 dnl
4775 dnl     POSIX.1-1990                            _POSIX_SOURCE
4776 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
4777 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
4778 dnl             Bindings Option
4779 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
4780 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
4781 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
4782 dnl
4783 dnl Parameters:
4784 dnl     $1 is the nominal value for _POSIX_C_SOURCE
4785 AC_DEFUN([CF_POSIX_C_SOURCE],
4786 [
4787 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
4788
4789 cf_save_CFLAGS="$CFLAGS"
4790 cf_save_CPPFLAGS="$CPPFLAGS"
4791
4792 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
4793 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
4794
4795 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
4796         CF_MSG_LOG(if the symbol is already defined go no further)
4797         AC_TRY_COMPILE([#include <sys/types.h>],[
4798 #ifndef _POSIX_C_SOURCE
4799 make an error
4800 #endif],
4801         [cf_cv_posix_c_source=no],
4802         [cf_want_posix_source=no
4803          case .$cf_POSIX_C_SOURCE in #(vi
4804          .[[12]]??*) #(vi
4805                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4806                 ;;
4807          .2) #(vi
4808                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4809                 cf_want_posix_source=yes
4810                 ;;
4811          .*)
4812                 cf_want_posix_source=yes
4813                 ;;
4814          esac
4815          if test "$cf_want_posix_source" = yes ; then
4816                 AC_TRY_COMPILE([#include <sys/types.h>],[
4817 #ifdef _POSIX_SOURCE
4818 make an error
4819 #endif],[],
4820                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
4821          fi
4822          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
4823          CFLAGS="$cf_trim_CFLAGS"
4824          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
4825          CF_MSG_LOG(if the second compile does not leave our definition intact error)
4826          AC_TRY_COMPILE([#include <sys/types.h>],[
4827 #ifndef _POSIX_C_SOURCE
4828 make an error
4829 #endif],,
4830          [cf_cv_posix_c_source=no])
4831          CFLAGS="$cf_save_CFLAGS"
4832          CPPFLAGS="$cf_save_CPPFLAGS"
4833         ])
4834 ])
4835
4836 if test "$cf_cv_posix_c_source" != no ; then
4837         CFLAGS="$cf_trim_CFLAGS"
4838         CPPFLAGS="$cf_trim_CPPFLAGS"
4839         CF_ADD_CFLAGS($cf_cv_posix_c_source)
4840 fi
4841
4842 ])dnl
4843 dnl ---------------------------------------------------------------------------
4844 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
4845 dnl ------------
4846 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
4847 dnl
4848 dnl $1 = symbol to test
4849 dnl $2 = value (if any) to use for a predefinition
4850 AC_DEFUN([CF_PREDEFINE],
4851 [
4852 AC_MSG_CHECKING(if we must define $1)
4853 AC_TRY_COMPILE([#include <sys/types.h>
4854 ],[
4855 #ifndef $1
4856 make an error
4857 #endif],[cf_result=no],[cf_result=yes])
4858 AC_MSG_RESULT($cf_result)
4859
4860 if test "$cf_result" = yes ; then
4861         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
4862 elif test "x$2" != "x" ; then
4863         AC_MSG_CHECKING(checking for compatible value versus $2)
4864         AC_TRY_COMPILE([#include <sys/types.h>
4865 ],[
4866 #if $1-$2 < 0
4867 make an error
4868 #endif],[cf_result=yes],[cf_result=no])
4869         AC_MSG_RESULT($cf_result)
4870         if test "$cf_result" = no ; then
4871                 # perhaps we can override it - try...
4872                 CPPFLAGS="$CPPFLAGS -D$1=$2"
4873         fi
4874 fi
4875 ])dnl
4876 dnl ---------------------------------------------------------------------------
4877 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
4878 dnl ------------
4879 dnl Append definitions and rules for the given programs to the subdirectory
4880 dnl Makefiles, and the recursion rule for the top-level Makefile.
4881 dnl
4882 dnl parameters
4883 dnl     $1 = script to run
4884 dnl     $2 = list of subdirectories
4885 dnl
4886 dnl variables
4887 dnl     $AWK
4888 AC_DEFUN([CF_PRG_RULES],
4889 [
4890 for cf_dir in $2
4891 do
4892         if test ! -d $srcdir/$cf_dir; then
4893                 continue
4894         elif test -f $srcdir/$cf_dir/programs; then
4895                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
4896         fi
4897 done
4898
4899 ])dnl
4900 dnl ---------------------------------------------------------------------------
4901 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
4902 dnl ----------
4903 dnl Check for archiver "ar".
4904 AC_DEFUN([CF_PROG_AR],[
4905 AC_CHECK_TOOL(AR, ar, ar)
4906 ])
4907 dnl ---------------------------------------------------------------------------
4908 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
4909 dnl -----------
4910 dnl Check for awk, ensure that the check found something.
4911 AC_DEFUN([CF_PROG_AWK],
4912 [
4913 AC_PROG_AWK
4914 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
4915 ])dnl
4916 dnl ---------------------------------------------------------------------------
4917 dnl CF_PROG_CC version: 3 updated: 2012/10/06 15:31:55
4918 dnl ----------
4919 dnl standard check for CC, plus followup sanity checks
4920 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
4921 AC_DEFUN([CF_PROG_CC],[
4922 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
4923 CF_GCC_VERSION
4924 CF_ACVERSION_CHECK(2.52,
4925         [AC_PROG_CC_STDC],
4926         [CF_ANSI_CC_REQD])
4927 CF_CC_ENV_FLAGS
4928 ])dnl
4929 dnl ---------------------------------------------------------------------------
4930 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
4931 dnl --------------
4932 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
4933 dnl the output file can be renamed, and allows for a shell variable that can
4934 dnl be used later.  The parameter is either CC or CXX.  The result is the
4935 dnl cache variable:
4936 dnl     $cf_cv_prog_CC_c_o
4937 dnl     $cf_cv_prog_CXX_c_o
4938 AC_DEFUN([CF_PROG_CC_C_O],
4939 [AC_REQUIRE([AC_PROG_CC])dnl
4940 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
4941 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
4942 [
4943 cat > conftest.$ac_ext <<CF_EOF
4944 #include <stdio.h>
4945 int main()
4946 {
4947         ${cf_cv_main_return:-return}(0);
4948 }
4949 CF_EOF
4950 # We do the test twice because some compilers refuse to overwrite an
4951 # existing .o file with -o, though they will create one.
4952 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
4953 if AC_TRY_EVAL(ac_try) &&
4954   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
4955 then
4956   eval cf_cv_prog_$1_c_o=yes
4957 else
4958   eval cf_cv_prog_$1_c_o=no
4959 fi
4960 rm -rf conftest*
4961 ])dnl
4962 if test $cf_cv_prog_$1_c_o = yes; then
4963   AC_MSG_RESULT([yes])
4964 else
4965   AC_MSG_RESULT([no])
4966 fi
4967 ])dnl
4968 dnl ---------------------------------------------------------------------------
4969 dnl CF_PROG_EGREP version: 1 updated: 2006/09/16 11:40:59
4970 dnl -------------
4971 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
4972 dnl This macro adds a check to ensure the script found something.
4973 AC_DEFUN([CF_PROG_EGREP],
4974 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
4975    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
4976     then ac_cv_prog_egrep='grep -E'
4977     else ac_cv_prog_egrep='egrep'
4978     fi])
4979  EGREP=$ac_cv_prog_egrep
4980  AC_SUBST([EGREP])
4981 test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
4982 ])dnl
4983 dnl ---------------------------------------------------------------------------
4984 dnl CF_PROG_GNAT version: 2 updated: 2011/10/22 14:01:47
4985 dnl ------------
4986 dnl Check for gnatmake, ensure that it is complete.
4987 AC_DEFUN([CF_PROG_GNAT],[
4988 cf_ada_make=gnatmake
4989 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
4990 if test "$ac_cv_prog_gnat_exists" = no; then
4991    cf_ada_make=
4992    cf_cv_prog_gnat_correct=no
4993 else
4994    CF_GNAT_VERSION
4995    AC_CHECK_PROG(M4_exists, m4, yes, no)
4996    if test "$ac_cv_prog_M4_exists" = no; then
4997       cf_cv_prog_gnat_correct=no
4998       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
4999    fi
5000    if test "$cf_cv_prog_gnat_correct" = yes; then
5001       AC_MSG_CHECKING(if GNAT works)
5002       CF_GNAT_TRY_RUN([procedure conftest;],
5003 [with Text_IO;
5004 with GNAT.OS_Lib;
5005 procedure conftest is
5006 begin
5007    Text_IO.Put ("Hello World");
5008    Text_IO.New_Line;
5009    GNAT.OS_Lib.OS_Exit (0);
5010 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
5011       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
5012    fi
5013 fi
5014
5015 AC_SUBST(cf_ada_make)
5016 ])dnl
5017 dnl ---------------------------------------------------------------------------
5018 dnl CF_PROG_INSTALL version: 5 updated: 2002/12/21 22:46:07
5019 dnl ---------------
5020 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
5021 dnl misc/tabset install won't work properly.  Usually this happens only when
5022 dnl using the fallback mkinstalldirs script
5023 AC_DEFUN([CF_PROG_INSTALL],
5024 [AC_PROG_INSTALL
5025 case $INSTALL in
5026 /*)
5027   ;;
5028 *)
5029   CF_DIRNAME(cf_dir,$INSTALL)
5030   test -z "$cf_dir" && cf_dir=.
5031   INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
5032   ;;
5033 esac
5034 ])dnl
5035 dnl ---------------------------------------------------------------------------
5036 dnl CF_PROG_LDCONFIG version: 3 updated: 2011/06/04 20:09:13
5037 dnl ----------------
5038 dnl Check for ldconfig, needed to fixup shared libraries that would be built
5039 dnl and then used in the install.
5040 AC_DEFUN([CF_PROG_LDCONFIG],[
5041 if test "$cross_compiling" = yes ; then
5042   LDCONFIG=:
5043 else
5044 case "$cf_cv_system_name" in #(vi
5045 dragonfly*|mirbsd*|freebsd*) #(vi
5046   test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
5047   ;;
5048 *) LDPATH=$PATH:/sbin:/usr/sbin
5049   AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
5050   ;;
5051 esac
5052 fi
5053 AC_SUBST(LDCONFIG)
5054 ])dnl
5055 dnl ---------------------------------------------------------------------------
5056 dnl CF_PROG_LINT version: 2 updated: 2009/08/12 04:43:14
5057 dnl ------------
5058 AC_DEFUN([CF_PROG_LINT],
5059 [
5060 AC_CHECK_PROGS(LINT, tdlint lint alint splint lclint)
5061 AC_SUBST(LINT_OPTS)
5062 ])dnl
5063 dnl ---------------------------------------------------------------------------
5064 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
5065 dnl ------------
5066 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
5067 dnl option if it is supported.
5068 AC_DEFUN([CF_PROG_LN_S],[
5069 AC_PROG_LN_S
5070 AC_MSG_CHECKING(if $LN_S -f options work)
5071
5072 rm -f conf$$.src conf$$dst
5073 echo >conf$$.dst
5074 echo first >conf$$.src
5075 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
5076         cf_prog_ln_sf=yes
5077 else
5078         cf_prog_ln_sf=no
5079 fi
5080 rm -f conf$$.dst conf$$src
5081 AC_MSG_RESULT($cf_prog_ln_sf)
5082
5083 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
5084 ])dnl
5085 dnl ---------------------------------------------------------------------------
5086 dnl CF_REGEX version: 10 updated: 2012/10/04 20:12:20
5087 dnl --------
5088 dnl Attempt to determine if we've got one of the flavors of regular-expression
5089 dnl code that we can support.
5090 AC_DEFUN([CF_REGEX],
5091 [
5092
5093 cf_regex_func=no
5094
5095 cf_regex_libs="regex re"
5096 case $host_os in #(vi
5097 mingw*)
5098         cf_regex_libs="gnurx $cf_regex_libs"
5099         ;;
5100 esac
5101
5102 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
5103         for cf_regex_lib in $cf_regex_libs
5104         do
5105                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
5106                                 CF_ADD_LIB($cf_regex_lib)
5107                                 cf_regex_func=regcomp
5108                                 break])
5109         done
5110 ])
5111
5112 if test "$cf_regex_func" = no ; then
5113         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
5114                 AC_CHECK_LIB(gen,compile,[
5115                                 CF_ADD_LIB(gen)
5116                                 cf_regex_func=compile])])
5117 fi
5118
5119 if test "$cf_regex_func" = no ; then
5120         AC_MSG_WARN(cannot find regular expression library)
5121 fi
5122
5123 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
5124
5125 cf_cv_regex_hdrs=no
5126 case $cf_regex_func in #(vi
5127 compile) #(vi
5128         for cf_regex_hdr in regexp.h regexpr.h
5129         do
5130                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
5131                         char *p = compile("", "", "", 0);
5132                         int x = step("", "");
5133                 ],[
5134                         cf_cv_regex_hdrs=$cf_regex_hdr
5135                         break
5136                 ])
5137         done
5138         ;;
5139 *)
5140         for cf_regex_hdr in regex.h
5141         do
5142                 AC_TRY_LINK([#include <sys/types.h>
5143 #include <$cf_regex_hdr>],[
5144                         regex_t *p;
5145                         int x = regcomp(p, "", 0);
5146                         int y = regexec(p, "", 0, 0, 0);
5147                         regfree(p);
5148                 ],[
5149                         cf_cv_regex_hdrs=$cf_regex_hdr
5150                         break
5151                 ])
5152         done
5153         ;;
5154 esac
5155
5156 ])
5157
5158 case $cf_cv_regex_hdrs in #(vi
5159     no)        AC_MSG_WARN(no regular expression header found) ;; #(vi
5160     regex.h)   AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;; #(vi
5161     regexp.h)  AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;; #(vi
5162     regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
5163 esac
5164 ])dnl
5165 dnl ---------------------------------------------------------------------------
5166 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
5167 dnl ----------------
5168 dnl Remove all -U and -D options that refer to the given symbol from a list
5169 dnl of C compiler options.  This works around the problem that not all
5170 dnl compilers process -U and -D options from left-to-right, so a -U option
5171 dnl cannot be used to cancel the effect of a preceding -D option.
5172 dnl
5173 dnl $1 = target (which could be the same as the source variable)
5174 dnl $2 = source (including '$')
5175 dnl $3 = symbol to remove
5176 define([CF_REMOVE_DEFINE],
5177 [
5178 $1=`echo "$2" | \
5179         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
5180                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
5181 ])dnl
5182 dnl ---------------------------------------------------------------------------
5183 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
5184 dnl -------------
5185 dnl Remove the given library from the symbol
5186 dnl
5187 dnl $1 = target (which could be the same as the source variable)
5188 dnl $2 = source (including '$')
5189 dnl $3 = library to remove
5190 define([CF_REMOVE_LIB],
5191 [
5192 # remove $3 library from $2
5193 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5194 ])dnl
5195 dnl ---------------------------------------------------------------------------
5196 dnl CF_RPATH_HACK version: 9 updated: 2011/02/13 13:31:33
5197 dnl -------------
5198 AC_DEFUN([CF_RPATH_HACK],
5199 [
5200 AC_REQUIRE([CF_LD_RPATH_OPT])
5201 AC_MSG_CHECKING(for updated LDFLAGS)
5202 if test -n "$LD_RPATH_OPT" ; then
5203         AC_MSG_RESULT(maybe)
5204
5205         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5206         cf_rpath_list="/usr/lib /lib"
5207         if test "$cf_ldd_prog" != no
5208         then
5209                 cf_rpath_oops=
5210
5211 AC_TRY_LINK([#include <stdio.h>],
5212                 [printf("Hello");],
5213                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort -u`
5214                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort -u`])
5215
5216                 # If we passed the link-test, but get a "not found" on a given library,
5217                 # this could be due to inept reconfiguration of gcc to make it only
5218                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
5219                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
5220                 # /usr/local libraries.
5221                 if test -n "$cf_rpath_oops"
5222                 then
5223                         for cf_rpath_src in $cf_rpath_oops
5224                         do
5225                                 for cf_rpath_dir in \
5226                                         /usr/local \
5227                                         /usr/pkg \
5228                                         /opt/sfw
5229                                 do
5230                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
5231                                         then
5232                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
5233                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
5234                                                 break
5235                                         fi
5236                                 done
5237                         done
5238                 fi
5239         fi
5240
5241         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5242
5243         CF_RPATH_HACK_2(LDFLAGS)
5244         CF_RPATH_HACK_2(LIBS)
5245
5246         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5247 fi
5248 AC_SUBST(EXTRA_LDFLAGS)
5249 ])dnl
5250 dnl ---------------------------------------------------------------------------
5251 dnl CF_RPATH_HACK_2 version: 6 updated: 2010/04/17 16:31:24
5252 dnl ---------------
5253 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
5254 dnl EXTRA_LDFLAGS for each -L option found.
5255 dnl
5256 dnl $cf_rpath_list contains a list of directories to ignore.
5257 dnl
5258 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
5259 dnl      but LIBS often has misplaced -L options.
5260 AC_DEFUN([CF_RPATH_HACK_2],
5261 [
5262 CF_VERBOSE(...checking $1 [$]$1)
5263
5264 cf_rpath_dst=
5265 for cf_rpath_src in [$]$1
5266 do
5267         case $cf_rpath_src in #(vi
5268         -L*) #(vi
5269
5270                 # check if this refers to a directory which we will ignore
5271                 cf_rpath_skip=no
5272                 if test -n "$cf_rpath_list"
5273                 then
5274                         for cf_rpath_item in $cf_rpath_list
5275                         do
5276                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
5277                                 then
5278                                         cf_rpath_skip=yes
5279                                         break
5280                                 fi
5281                         done
5282                 fi
5283
5284                 if test "$cf_rpath_skip" = no
5285                 then
5286                         # transform the option
5287                         if test "$LD_RPATH_OPT" = "-R " ; then
5288                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
5289                         else
5290                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
5291                         fi
5292
5293                         # if we have not already added this, add it now
5294                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
5295                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
5296                         then
5297                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
5298                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
5299                         fi
5300                 fi
5301                 ;;
5302         esac
5303         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
5304 done
5305 $1=$cf_rpath_dst
5306
5307 CF_VERBOSE(...checked $1 [$]$1)
5308 AC_SUBST(EXTRA_LDFLAGS)
5309 ])dnl
5310 dnl ---------------------------------------------------------------------------
5311 dnl CF_SHARED_OPTS version: 72 updated: 2013/01/26 16:26:12
5312 dnl --------------
5313 dnl --------------
5314 dnl Attempt to determine the appropriate CC/LD options for creating a shared
5315 dnl library.
5316 dnl
5317 dnl Note: ${LOCAL_LDFLAGS} is used to link executables that will run within the
5318 dnl build-tree, i.e., by making use of the libraries that are compiled in ../lib
5319 dnl We avoid compiling-in a ../lib path for the shared library since that can
5320 dnl lead to unexpected results at runtime.
5321 dnl ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared libraries
5322 dnl are compiled in ../../lib
5323 dnl
5324 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
5325 dnl to install symbolic links to the rel/abi versions of shared libraries.
5326 dnl
5327 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
5328 dnl version when making symbolic links.
5329 dnl
5330 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
5331 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
5332 dnl (ex: libncurses.so.<ver>).
5333 dnl
5334 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
5335 AC_DEFUN([CF_SHARED_OPTS],
5336 [
5337         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
5338         AC_REQUIRE([CF_LD_RPATH_OPT])
5339         LOCAL_LDFLAGS=
5340         LOCAL_LDFLAGS2=
5341         LD_SHARED_OPTS=
5342         INSTALL_LIB="-m 644"
5343
5344         cf_cv_do_symlinks=no
5345         cf_ld_rpath_opt=
5346         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
5347
5348         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
5349         AC_ARG_WITH(shlib-version,
5350         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
5351         [test -z "$withval" && withval=auto
5352         case $withval in #(vi
5353         yes) #(vi
5354                 cf_cv_shlib_version=auto
5355                 ;;
5356         rel|abi|auto|no) #(vi
5357                 cf_cv_shlib_version=$withval
5358                 ;;
5359         *)
5360                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
5361                 ;;
5362         esac
5363         ],[cf_cv_shlib_version=auto])
5364         AC_MSG_RESULT($cf_cv_shlib_version)
5365
5366         cf_cv_rm_so_locs=no
5367         cf_try_cflags=
5368
5369         # Some less-capable ports of gcc support only -fpic
5370         CC_SHARED_OPTS=
5371         if test "$GCC" = yes
5372         then
5373                 AC_MSG_CHECKING(which $CC option to use)
5374                 cf_save_CFLAGS="$CFLAGS"
5375                 for CC_SHARED_OPTS in -fPIC -fpic ''
5376                 do
5377                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
5378                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
5379                 done
5380                 AC_MSG_RESULT($CC_SHARED_OPTS)
5381                 CFLAGS="$cf_save_CFLAGS"
5382         fi
5383
5384         cf_cv_shlib_version_infix=no
5385
5386         case $cf_cv_system_name in #(vi
5387         aix4.[3-9]*|aix[[5-7]]*) #(vi
5388                 if test "$GCC" = yes; then
5389                         CC_SHARED_OPTS=
5390                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5391                 else
5392                         # CC_SHARED_OPTS='-qpic=large -G'
5393                         # perhaps "-bM:SRE -bnoentry -bexpall"
5394                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5395                 fi
5396                 ;;
5397         beos*) #(vi
5398                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
5399                 ;;
5400         cygwin*) #(vi
5401                 CC_SHARED_OPTS=
5402                 MK_SHARED_LIB='sh ../mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5403                 cf_cv_shlib_version=cygdll
5404                 cf_cv_shlib_version_infix=cygdll
5405                 cat >mk_shared_lib.sh <<-CF_EOF
5406                 #!/bin/sh
5407                 SHARED_LIB=\[$]1
5408                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5409                 shift
5410                 cat <<-EOF
5411                 Linking shared library
5412                 ** SHARED_LIB \[$]SHARED_LIB
5413                 ** IMPORT_LIB \[$]IMPORT_LIB
5414 EOF
5415                 exec \[$]* -shared -Wl,--out-implib=../lib/\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o ../lib/\[$]{SHARED_LIB}
5416 CF_EOF
5417                 chmod +x mk_shared_lib.sh
5418                 ;;
5419         darwin*) #(vi
5420                 cf_try_cflags="no-cpp-precomp"
5421                 CC_SHARED_OPTS="-dynamic"
5422                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
5423                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
5424                 cf_cv_shlib_version_infix=yes
5425                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
5426                         cf_save_LDFLAGS=$LDFLAGS
5427                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5428                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
5429                                 LDFLAGS=$cf_save_LDFLAGS])
5430                 if test $cf_cv_ldflags_search_paths_first = yes; then
5431                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5432                 fi
5433                 ;;
5434         hpux[[7-8]]*) #(vi
5435                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
5436                 if test "$GCC" != yes; then
5437                         CC_SHARED_OPTS='+Z'
5438                 fi
5439                 MK_SHARED_LIB='${LD} -b -o $[@]'
5440                 INSTALL_LIB="-m 555"
5441                 ;;
5442         hpux*) #(vi
5443                 # (tested with gcc 2.7.2 -- I don't have c89)
5444                 if test "$GCC" = yes; then
5445                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
5446                 else
5447                         CC_SHARED_OPTS='+Z'
5448                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
5449                 fi
5450                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
5451                 # HP-UX shared libraries must be executable, and should be
5452                 # readonly to exploit a quirk in the memory manager.
5453                 INSTALL_LIB="-m 555"
5454                 ;;
5455         interix*)
5456                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5457                 if test "$cf_cv_shlib_version" = rel; then
5458                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
5459                 else
5460                         cf_shared_soname='`basename $@`'
5461                 fi
5462                 CC_SHARED_OPTS=
5463                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
5464                 ;;
5465         irix*) #(vi
5466                 if test "$cf_cv_enable_rpath" = yes ; then
5467                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5468                 fi
5469                 # tested with IRIX 5.2 and 'cc'.
5470                 if test "$GCC" != yes; then
5471                         CC_SHARED_OPTS='-KPIC'
5472                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
5473                 else
5474                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
5475                 fi
5476                 cf_cv_rm_so_locs=yes
5477                 ;;
5478         linux*|gnu*|k*bsd*-gnu) #(vi
5479                 if test "$DFT_LWR_MODEL" = "shared" ; then
5480                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5481                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5482                 fi
5483                 if test "$cf_cv_enable_rpath" = yes ; then
5484                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5485                 fi
5486                 CF_SHARED_SONAME
5487                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5488                 ;;
5489         mingw*) #(vi
5490                 cf_cv_shlib_version=mingw
5491                 cf_cv_shlib_version_infix=mingw
5492                 CC_SHARED_OPTS=
5493                 MK_SHARED_LIB='sh ../mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5494                 #MK_SHARED_LIB='${CC} ${CFLAGS} -mdll -Wl,-soname,'$cf_cv_shared_soname',-stats -o $[@]'
5495                 #MK_SHARED_LIB='${DLLTOOL} --export-all-symbols --output-exp --output-lib $[@]'
5496                 cat >mk_shared_lib.sh <<-CF_EOF
5497                 #!/bin/sh
5498                 SHARED_LIB=\[$]1
5499                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5500                 shift
5501                 cat <<-EOF
5502                 Linking shared library
5503                 ** SHARED_LIB \[$]SHARED_LIB
5504                 ** IMPORT_LIB \[$]IMPORT_LIB
5505 EOF
5506                 exec \[$]* -shared -Wl,--out-implib=../lib/\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o ../lib/\[$]{SHARED_LIB}
5507 CF_EOF
5508                 chmod +x mk_shared_lib.sh
5509                 ;;
5510         openbsd[[2-9]].*|mirbsd*) #(vi
5511                 if test "$DFT_LWR_MODEL" = "shared" ; then
5512                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5513                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5514                 fi
5515                 if test "$cf_cv_enable_rpath" = yes ; then
5516                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5517                 fi
5518                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5519                 CF_SHARED_SONAME
5520                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5521                 ;;
5522         nto-qnx*|openbsd*|freebsd[[12]].*) #(vi
5523                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5524                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
5525                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5526                 ;;
5527         dragonfly*|freebsd*) #(vi
5528                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5529                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5530                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5531                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
5532                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5533                 fi
5534                 CF_SHARED_SONAME
5535                 MK_SHARED_LIB='${LD} -shared -Bshareable -soname=`basename $[@]` -o $[@]'
5536                 ;;
5537         netbsd*) #(vi
5538                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5539                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5540                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5541                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5542                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5543                         if test "$cf_cv_shlib_version" = auto; then
5544                         if test -f /usr/libexec/ld.elf_so; then
5545                                 cf_cv_shlib_version=abi
5546                         else
5547                                 cf_cv_shlib_version=rel
5548                         fi
5549                         fi
5550                         CF_SHARED_SONAME
5551                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
5552                 else
5553                         MK_SHARED_LIB='${LD} -shared -Bshareable -o $[@]'
5554                 fi
5555                 ;;
5556         osf*|mls+*) #(vi
5557                 # tested with OSF/1 V3.2 and 'cc'
5558                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
5559                 # link with shared libs).
5560                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
5561                 case $host_os in #(vi
5562                 osf4*)
5563                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
5564                         ;;
5565                 esac
5566                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
5567                 if test "$DFT_LWR_MODEL" = "shared" ; then
5568                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5569                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5570                 fi
5571                 cf_cv_rm_so_locs=yes
5572                 ;;
5573         sco3.2v5*)  # (also uw2* and UW7: hops 13-Apr-98
5574                 # tested with osr5.0.5
5575                 if test "$GCC" != yes; then
5576                         CC_SHARED_OPTS='-belf -KPIC'
5577                 fi
5578                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
5579                 if test "$cf_cv_enable_rpath" = yes ; then
5580                         # only way is to set LD_RUN_PATH but no switch for it
5581                         RUN_PATH=$libdir
5582                 fi
5583                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5584                 LINK_PROGS='LD_RUN_PATH=${libdir}'
5585                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
5586                 ;;
5587         sunos4*) #(vi
5588                 # tested with SunOS 4.1.1 and gcc 2.7.0
5589                 if test "$GCC" != yes; then
5590                         CC_SHARED_OPTS='-KPIC'
5591                 fi
5592                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
5593                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5594                 ;;
5595         solaris2*) #(vi
5596                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
5597                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
5598                 if test "$DFT_LWR_MODEL" = "shared" ; then
5599                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
5600                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5601                 fi
5602                 if test "$cf_cv_enable_rpath" = yes ; then
5603                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
5604                 fi
5605                 CF_SHARED_SONAME
5606                 if test "$GCC" != yes; then
5607                         cf_save_CFLAGS="$CFLAGS"
5608                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
5609                         do
5610                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
5611                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
5612                         done
5613                         CFLAGS="$cf_save_CFLAGS"
5614                         CC_SHARED_OPTS=$cf_shared_opts
5615                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5616                 else
5617                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5618                 fi
5619                 ;;
5620         sysv5uw7*|unix_sv*) #(vi
5621                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
5622                 if test "$GCC" != yes; then
5623                         CC_SHARED_OPTS='-KPIC'
5624                 fi
5625                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
5626                 ;;
5627         *)
5628                 CC_SHARED_OPTS='unknown'
5629                 MK_SHARED_LIB='echo unknown'
5630                 ;;
5631         esac
5632
5633         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
5634         case "$cf_cv_shlib_version" in #(vi
5635         rel|abi)
5636                 case "$MK_SHARED_LIB" in #(vi
5637                 *'-o $[@]') #(vi
5638                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
5639                         ;;
5640                 *)
5641                         AC_MSG_WARN(ignored --with-shlib-version)
5642                         ;;
5643                 esac
5644                 ;;
5645         esac
5646
5647         if test -n "$cf_try_cflags"
5648         then
5649 cat > conftest.$ac_ext <<EOF
5650 #line __oline__ "${as_me:-configure}"
5651 #include <stdio.h>
5652 int main(int argc, char *argv[[]])
5653 {
5654         printf("hello\n");
5655         return (argv[[argc-1]] == 0) ;
5656 }
5657 EOF
5658                 cf_save_CFLAGS="$CFLAGS"
5659                 for cf_opt in $cf_try_cflags
5660                 do
5661                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
5662                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
5663                         if AC_TRY_EVAL(ac_compile); then
5664                                 AC_MSG_RESULT(yes)
5665                                 cf_save_CFLAGS="$CFLAGS"
5666                         else
5667                                 AC_MSG_RESULT(no)
5668                         fi
5669                 done
5670                 CFLAGS="$cf_save_CFLAGS"
5671         fi
5672
5673
5674         # RPATH_LIST is a colon-separated list of directories
5675         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
5676         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
5677
5678         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
5679         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
5680
5681         AC_SUBST(CC_SHARED_OPTS)
5682         AC_SUBST(LD_RPATH_OPT)
5683         AC_SUBST(LD_SHARED_OPTS)
5684         AC_SUBST(MK_SHARED_LIB)
5685         AC_SUBST(LINK_PROGS)
5686         AC_SUBST(LINK_TESTS)
5687         AC_SUBST(EXTRA_LDFLAGS)
5688         AC_SUBST(LOCAL_LDFLAGS)
5689         AC_SUBST(LOCAL_LDFLAGS2)
5690         AC_SUBST(INSTALL_LIB)
5691         AC_SUBST(RPATH_LIST)
5692 ])dnl
5693 dnl ---------------------------------------------------------------------------
5694 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
5695 dnl ----------------
5696 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
5697 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
5698 dnl option.
5699 dnl
5700 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
5701 dnl If missing, use "rel".
5702 define([CF_SHARED_SONAME],
5703 [
5704         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
5705         if test "$cf_cv_shlib_version" = rel; then
5706                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
5707         else
5708                 cf_cv_shared_soname='`basename $[@]`'
5709         fi
5710 ])
5711 dnl ---------------------------------------------------------------------------
5712 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
5713 dnl -----------
5714 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
5715 dnl programs need this test).
5716 dnl
5717 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
5718 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
5719 dnl winsize declaration is left alone - we may revisit this if Apple choose to
5720 dnl break that part of the interface as well.
5721 AC_DEFUN([CF_SIGWINCH],
5722 [
5723 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
5724         AC_TRY_COMPILE([
5725 #include <sys/types.h>
5726 #include <sys/signal.h>
5727 ],[int x = SIGWINCH],
5728         [cf_cv_define_sigwinch=yes],
5729         [AC_TRY_COMPILE([
5730 #undef _XOPEN_SOURCE
5731 #undef _POSIX_SOURCE
5732 #undef _POSIX_C_SOURCE
5733 #include <sys/types.h>
5734 #include <sys/signal.h>
5735 ],[int x = SIGWINCH],
5736         [cf_cv_define_sigwinch=maybe],
5737         [cf_cv_define_sigwinch=no])
5738 ])
5739 ])
5740
5741 if test "$cf_cv_define_sigwinch" = maybe ; then
5742 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
5743 cf_cv_fixup_sigwinch=unknown
5744 cf_sigwinch=32
5745 while test $cf_sigwinch != 1
5746 do
5747         AC_TRY_COMPILE([
5748 #undef _XOPEN_SOURCE
5749 #undef _POSIX_SOURCE
5750 #undef _POSIX_C_SOURCE
5751 #include <sys/types.h>
5752 #include <sys/signal.h>
5753 ],[
5754 #if SIGWINCH != $cf_sigwinch
5755 make an error
5756 #endif
5757 int x = SIGWINCH],
5758         [cf_cv_fixup_sigwinch=$cf_sigwinch
5759          break])
5760
5761 cf_sigwinch=`expr $cf_sigwinch - 1`
5762 done
5763 ])
5764
5765         if test "$cf_cv_fixup_sigwinch" != unknown ; then
5766                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
5767         fi
5768 fi
5769 ])dnl
5770 dnl ---------------------------------------------------------------------------
5771 dnl CF_SIG_ATOMIC_T version: 3 updated: 2012/10/04 20:12:20
5772 dnl ---------------
5773 dnl signal handler, but there are some gcc depedencies in that recommendation.
5774 dnl Try anyway.
5775 AC_DEFUN([CF_SIG_ATOMIC_T],
5776 [
5777 AC_MSG_CHECKING(for signal global datatype)
5778 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
5779         for cf_type in \
5780                 "volatile sig_atomic_t" \
5781                 "sig_atomic_t" \
5782                 "int"
5783         do
5784         AC_TRY_COMPILE([
5785 #include <sys/types.h>
5786 #include <signal.h>
5787 #include <stdio.h>
5788
5789 extern $cf_type x;
5790 $cf_type x;
5791 static void handler(int sig)
5792 {
5793         x = 5;
5794 }],
5795                 [signal(SIGINT, handler);
5796                  x = 1],
5797                 [cf_cv_sig_atomic_t=$cf_type],
5798                 [cf_cv_sig_atomic_t=no])
5799                 test "$cf_cv_sig_atomic_t" != no && break
5800         done
5801         ])
5802 AC_MSG_RESULT($cf_cv_sig_atomic_t)
5803 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
5804 ])dnl
5805 dnl ---------------------------------------------------------------------------
5806 dnl CF_SIZECHANGE version: 9 updated: 2012/10/06 11:17:15
5807 dnl -------------
5808 dnl Check for definitions & structures needed for window size-changing
5809 dnl FIXME: check that this works with "snake" (HP-UX 10.x)
5810 AC_DEFUN([CF_SIZECHANGE],
5811 [
5812 AC_REQUIRE([CF_STRUCT_TERMIOS])
5813 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
5814     cf_cv_sizechange=unknown
5815     cf_save_CPPFLAGS="$CPPFLAGS"
5816
5817 for cf_opts in "" "NEED_PTEM_H"
5818 do
5819
5820     CPPFLAGS="$cf_save_CPPFLAGS"
5821     test -n "$cf_opts" && CPPFLAGS="$CPPFLAGS -D$cf_opts"
5822     AC_TRY_COMPILE([#include <sys/types.h>
5823 #ifdef HAVE_TERMIOS_H
5824 #include <termios.h>
5825 #else
5826 #ifdef HAVE_TERMIO_H
5827 #include <termio.h>
5828 #endif
5829 #endif
5830 #ifdef NEED_PTEM_H
5831 /* This is a workaround for SCO:  they neglected to define struct winsize in
5832  * termios.h -- it's only in termio.h and ptem.h
5833  */
5834 #include        <sys/stream.h>
5835 #include        <sys/ptem.h>
5836 #endif
5837 #if !defined(sun) || !defined(HAVE_TERMIOS_H)
5838 #include <sys/ioctl.h>
5839 #endif
5840 ],[
5841 #ifdef TIOCGSIZE
5842         struct ttysize win;     /* FIXME: what system is this? */
5843         int y = win.ts_lines;
5844         int x = win.ts_cols;
5845 #else
5846 #ifdef TIOCGWINSZ
5847         struct winsize win;
5848         int y = win.ws_row;
5849         int x = win.ws_col;
5850 #else
5851         no TIOCGSIZE or TIOCGWINSZ
5852 #endif /* TIOCGWINSZ */
5853 #endif /* TIOCGSIZE */
5854         ],
5855         [cf_cv_sizechange=yes],
5856         [cf_cv_sizechange=no])
5857
5858         CPPFLAGS="$cf_save_CPPFLAGS"
5859         if test "$cf_cv_sizechange" = yes ; then
5860                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
5861                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
5862                 break
5863         fi
5864 done
5865 ])
5866 if test "$cf_cv_sizechange" != no ; then
5867         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechar declarations are provided])
5868         case $cf_cv_sizechange in #(vi
5869         NEED*)
5870                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
5871                 ;;
5872         esac
5873 fi
5874 ])dnl
5875 dnl ---------------------------------------------------------------------------
5876 dnl CF_SRC_MODULES version: 26 updated: 2012/01/07 15:08:24
5877 dnl --------------
5878 dnl For each parameter, test if the source-directory exists, and if it contains
5879 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
5880 dnl use in CF_LIB_RULES.
5881 dnl
5882 dnl This uses the configured value to make the lists SRC_SUBDIRS and
5883 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
5884 AC_DEFUN([CF_SRC_MODULES],
5885 [
5886 AC_MSG_CHECKING(for src modules)
5887
5888 # dependencies and linker-arguments for test-programs
5889 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
5890 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
5891 if test "$DFT_LWR_MODEL" = "libtool"; then
5892         TEST_ARGS="${TEST_DEPS}"
5893         TEST_ARG2="${TEST_DEP2}"
5894 else
5895         TEST_ARGS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
5896         TEST_ARG2="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARG2"
5897 fi
5898
5899 PC_MODULES_TO_MAKE="ncurses${DFT_ARG_SUFFIX}"
5900 cf_cv_src_modules=
5901 for cf_dir in $1
5902 do
5903         if test -f $srcdir/$cf_dir/modules; then
5904
5905                 # We may/may not have tack in the distribution, though the
5906                 # makefile is.
5907                 if test $cf_dir = tack ; then
5908                         if test ! -f $srcdir/${cf_dir}/${cf_dir}.h; then
5909                                 continue
5910                         fi
5911                 fi
5912
5913                 if test -z "$cf_cv_src_modules"; then
5914                         cf_cv_src_modules=$cf_dir
5915                 else
5916                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
5917                 fi
5918
5919                 # Make the ncurses_cfg.h file record the library interface files as
5920                 # well.  These are header files that are the same name as their
5921                 # directory.  Ncurses is the only library that does not follow
5922                 # that pattern.
5923                 if test $cf_dir = tack ; then
5924                         continue
5925                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
5926                         CF_UPPER(cf_have_include,$cf_dir)
5927                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
5928                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
5929                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
5930                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
5931                         if test "$DFT_LWR_MODEL" = "libtool"; then
5932                                 TEST_ARGS="${TEST_DEPS}"
5933                                 TEST_ARG2="${TEST_DEP2}"
5934                         else
5935                                 TEST_ARGS="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARGS"
5936                                 TEST_ARG2="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARG2"
5937                         fi
5938                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${DFT_ARG_SUFFIX}"
5939                 fi
5940         fi
5941 done
5942 AC_MSG_RESULT($cf_cv_src_modules)
5943
5944 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
5945 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
5946
5947 AC_SUBST(TEST_ARGS)
5948 AC_SUBST(TEST_DEPS)
5949
5950 AC_SUBST(TEST_ARG2)
5951 AC_SUBST(TEST_DEP2)
5952
5953 SRC_SUBDIRS=
5954 if test "x$cf_with_manpages" != xno ; then
5955         SRC_SUBDIRS="$SRC_SUBDIRS man"
5956 fi
5957 SRC_SUBDIRS="$SRC_SUBDIRS include"
5958 for cf_dir in $cf_cv_src_modules
5959 do
5960         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
5961 done
5962 if test "x$cf_with_tests" != "xno" ; then
5963         SRC_SUBDIRS="$SRC_SUBDIRS test"
5964 fi
5965 test -z "$MAKE_TERMINFO" && SRC_SUBDIRS="$SRC_SUBDIRS misc"
5966 if test "$cf_with_cxx_binding" != no; then
5967         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${DFT_ARG_SUFFIX}"
5968         SRC_SUBDIRS="$SRC_SUBDIRS c++"
5969 fi
5970
5971 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
5972 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
5973
5974 AC_SUBST(PC_MODULES_TO_MAKE)
5975
5976 ADA_SUBDIRS=
5977 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
5978         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
5979         ADA_SUBDIRS="gen src"
5980         if test "x$cf_with_tests" != "xno" ; then
5981                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
5982         fi
5983 fi
5984
5985 SUB_MAKEFILES=
5986 for cf_dir in $SRC_SUBDIRS
5987 do
5988         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
5989 done
5990
5991 if test -n "$ADA_SUBDIRS"; then
5992         for cf_dir in $ADA_SUBDIRS
5993         do
5994                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
5995         done
5996         AC_SUBST(ADA_SUBDIRS)
5997 fi
5998 ])dnl
5999 dnl ---------------------------------------------------------------------------
6000 dnl CF_STDCPP_LIBRARY version: 7 updated: 2010/05/29 16:31:02
6001 dnl -----------------
6002 dnl Check for -lstdc++, which is GNU's standard C++ library.
6003 AC_DEFUN([CF_STDCPP_LIBRARY],
6004 [
6005 if test -n "$GXX" ; then
6006 case $cf_cv_system_name in #(vi
6007 os2*) #(vi
6008         cf_stdcpp_libname=stdcpp
6009         ;;
6010 *)
6011         cf_stdcpp_libname=stdc++
6012         ;;
6013 esac
6014 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
6015         cf_save="$LIBS"
6016         CF_ADD_LIB($cf_stdcpp_libname)
6017 AC_TRY_LINK([
6018 #include <strstream.h>],[
6019 char buf[80];
6020 strstreambuf foo(buf, sizeof(buf))
6021 ],
6022         [cf_cv_libstdcpp=yes],
6023         [cf_cv_libstdcpp=no])
6024         LIBS="$cf_save"
6025 ])
6026 test "$cf_cv_libstdcpp" = yes && CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS)
6027 fi
6028 ])dnl
6029 dnl ---------------------------------------------------------------------------
6030 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
6031 dnl --------------
6032 dnl     Remove "-g" option from the compiler options
6033 AC_DEFUN([CF_STRIP_G_OPT],
6034 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
6035 dnl ---------------------------------------------------------------------------
6036 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
6037 dnl -------------------
6038 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
6039 dnl do this if we've found the sigaction function.
6040 AC_DEFUN([CF_STRUCT_SIGACTION],[
6041 AC_REQUIRE([CF_XOPEN_SOURCE])
6042
6043 if test "$ac_cv_func_sigaction" = yes; then
6044 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
6045 AC_TRY_COMPILE([
6046 #include <sys/types.h>
6047 #include <signal.h>],
6048         [struct sigaction act],
6049         [sigact_bad=no],
6050         [
6051 AC_TRY_COMPILE([
6052 #define _POSIX_SOURCE
6053 #include <sys/types.h>
6054 #include <signal.h>],
6055         [struct sigaction act],
6056         [sigact_bad=yes
6057          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
6058          [sigact_bad=unknown])])
6059 AC_MSG_RESULT($sigact_bad)
6060 fi
6061 ])dnl
6062 dnl ---------------------------------------------------------------------------
6063 dnl CF_STRUCT_TERMIOS version: 7 updated: 2012/10/06 17:56:13
6064 dnl -----------------
6065 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
6066 AC_DEFUN([CF_STRUCT_TERMIOS],[
6067 AC_REQUIRE([CF_XOPEN_SOURCE])
6068
6069 AC_CHECK_HEADERS( \
6070 termio.h \
6071 termios.h \
6072 unistd.h \
6073 )
6074
6075 if test "$ISC" = yes ; then
6076         AC_CHECK_HEADERS( sys/termio.h )
6077 fi
6078 if test "$ac_cv_header_termios_h" = yes ; then
6079         case "$CFLAGS $CPPFLAGS" in
6080         *-D_POSIX_SOURCE*)
6081                 termios_bad=dunno ;;
6082         *)      termios_bad=maybe ;;
6083         esac
6084         if test "$termios_bad" = maybe ; then
6085         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
6086         AC_TRY_COMPILE([#include <termios.h>],
6087                 [struct termios foo; int x = foo.c_iflag],
6088                 termios_bad=no, [
6089                 AC_TRY_COMPILE([
6090 #define _POSIX_SOURCE
6091 #include <termios.h>],
6092                         [struct termios foo; int x = foo.c_iflag],
6093                         termios_bad=unknown,
6094                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
6095                         ])
6096         AC_MSG_RESULT($termios_bad)
6097         fi
6098 fi
6099 ])dnl
6100 dnl ---------------------------------------------------------------------------
6101 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
6102 dnl --------------
6103 dnl Construct a search-list for a nonstandard header/lib-file
6104 dnl     $1 = the variable to return as result
6105 dnl     $2 = the package name
6106 dnl     $3 = the subdirectory, e.g., bin, include or lib
6107 AC_DEFUN([CF_SUBDIR_PATH],
6108 [
6109 $1=
6110
6111 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
6112 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
6113 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
6114 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
6115 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
6116 ])dnl
6117 dnl ---------------------------------------------------------------------------
6118 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
6119 dnl -----------
6120 dnl     Shorthand macro for substituting things that the user may override
6121 dnl     with an environment variable.
6122 dnl
6123 dnl     $1 = condition to pass to "test"
6124 dnl     $2 = environment variable
6125 dnl     $3 = value if the test succeeds
6126 dnl     $4 = value if the test fails
6127 AC_DEFUN([CF_SUBST_IF],
6128 [
6129 if test $1 ; then
6130         $2=$3
6131 ifelse($4,,,[else
6132         $2=$4])
6133 fi
6134 AC_SUBST($2)
6135 ])dnl
6136 dnl ---------------------------------------------------------------------------
6137 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
6138 dnl ------------------------
6139 dnl Get the version-number for use in shared-library naming, etc.
6140 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
6141 [
6142 AC_REQUIRE([CF_PROG_EGREP])
6143 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6144 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6145 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6146 cf_cv_abi_version=${NCURSES_MAJOR}
6147 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
6148 dnl Show the computed version, for logging
6149 cf_cv_timestamp=`date`
6150 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
6151 dnl We need these values in the generated headers
6152 AC_SUBST(NCURSES_MAJOR)
6153 AC_SUBST(NCURSES_MINOR)
6154 AC_SUBST(NCURSES_PATCH)
6155 dnl We need these values in the generated makefiles
6156 AC_SUBST(cf_cv_rel_version)
6157 AC_SUBST(cf_cv_abi_version)
6158 AC_SUBST(cf_cv_builtin_bool)
6159 AC_SUBST(cf_cv_header_stdbool_h)
6160 AC_SUBST(cf_cv_type_of_bool)dnl
6161 ])dnl
6162 dnl ---------------------------------------------------------------------------
6163 dnl CF_SYS_TIME_SELECT version: 5 updated: 2012/10/04 05:24:07
6164 dnl ------------------
6165 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
6166 dnl older SCO configurations.
6167 AC_DEFUN([CF_SYS_TIME_SELECT],
6168 [
6169 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
6170 AC_CACHE_VAL(cf_cv_sys_time_select,[
6171 AC_TRY_COMPILE([
6172 #include <sys/types.h>
6173 #ifdef HAVE_SYS_TIME_H
6174 #include <sys/time.h>
6175 #endif
6176 #ifdef HAVE_SYS_SELECT_H
6177 #include <sys/select.h>
6178 #endif
6179 ],[],[cf_cv_sys_time_select=yes],
6180      [cf_cv_sys_time_select=no])
6181      ])
6182 AC_MSG_RESULT($cf_cv_sys_time_select)
6183 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
6184 ])dnl
6185 dnl ---------------------------------------------------------------------------
6186 dnl CF_TOP_BUILDDIR version: 1 updated: 2006/10/15 16:33:23
6187 dnl ---------------
6188 dnl Define a top_builddir symbol, for applications that need an absolute path.
6189 AC_DEFUN([CF_TOP_BUILDDIR],
6190 [
6191 top_builddir=`pwd`
6192 AC_SUBST(top_builddir)
6193 ])dnl
6194 dnl ---------------------------------------------------------------------------
6195 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
6196 dnl -------------------
6197 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
6198 dnl can define it successfully.
6199 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
6200 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
6201         AC_TRY_COMPILE([
6202 #include <stdlib.h>
6203 #include <string.h>
6204 #include <sys/types.h>
6205 ],[
6206 #ifndef _XOPEN_SOURCE
6207 make an error
6208 #endif],
6209         [cf_cv_xopen_source=no],
6210         [cf_save="$CPPFLAGS"
6211          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6212          AC_TRY_COMPILE([
6213 #include <stdlib.h>
6214 #include <string.h>
6215 #include <sys/types.h>
6216 ],[
6217 #ifdef _XOPEN_SOURCE
6218 make an error
6219 #endif],
6220         [cf_cv_xopen_source=no],
6221         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
6222         CPPFLAGS="$cf_save"
6223         ])
6224 ])
6225
6226 if test "$cf_cv_xopen_source" != no ; then
6227         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
6228         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
6229         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
6230         CF_ADD_CFLAGS($cf_temp_xopen_source)
6231 fi
6232 ])
6233 dnl ---------------------------------------------------------------------------
6234 dnl CF_TYPEOF_CHTYPE version: 9 updated: 2012/10/06 17:56:13
6235 dnl ----------------
6236 dnl Determine the type we should use for chtype (and attr_t, which is treated
6237 dnl as the same thing).  We want around 32 bits, so on most machines want a
6238 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
6239 dnl wide characters, we have to have a type compatible with that, as well.
6240 AC_DEFUN([CF_TYPEOF_CHTYPE],
6241 [
6242 AC_MSG_CHECKING([for type of chtype])
6243 AC_CACHE_VAL(cf_cv_typeof_chtype,[
6244                 AC_TRY_RUN([
6245 #define WANT_BITS 31
6246 #include <stdio.h>
6247 int main()
6248 {
6249         FILE *fp = fopen("cf_test.out", "w");
6250         if (fp != 0) {
6251                 char *result = "long";
6252                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
6253                         int n;
6254                         unsigned int x, y;
6255                         for (n = 0; n < WANT_BITS; n++) {
6256                                 x = (1 << n);
6257                                 y = (x >> n);
6258                                 if (y != 1 || x == 0) {
6259                                         x = 0;
6260                                         break;
6261                                 }
6262                         }
6263                         /*
6264                          * If x is nonzero, an int is big enough for the bits
6265                          * that we want.
6266                          */
6267                         result = (x != 0) ? "int" : "long";
6268                 }
6269                 fputs(result, fp);
6270                 fclose(fp);
6271         }
6272         ${cf_cv_main_return:-return}(0);
6273 }
6274                 ],
6275                 [cf_cv_typeof_chtype=`cat cf_test.out`],
6276                 [cf_cv_typeof_chtype=long],
6277                 [cf_cv_typeof_chtype=long])
6278                 rm -f cf_test.out
6279         ])
6280 AC_MSG_RESULT($cf_cv_typeof_chtype)
6281
6282 AC_SUBST(cf_cv_typeof_chtype)
6283 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
6284 ])dnl
6285 dnl ---------------------------------------------------------------------------
6286 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
6287 dnl -----------------
6288 dnl
6289 AC_DEFUN([CF_TYPE_SIGACTION],
6290 [
6291 AC_MSG_CHECKING([for type sigaction_t])
6292 AC_CACHE_VAL(cf_cv_type_sigaction,[
6293         AC_TRY_COMPILE([
6294 #include <signal.h>],
6295                 [sigaction_t x],
6296                 [cf_cv_type_sigaction=yes],
6297                 [cf_cv_type_sigaction=no])])
6298 AC_MSG_RESULT($cf_cv_type_sigaction)
6299 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
6300 ])dnl
6301 dnl ---------------------------------------------------------------------------
6302 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
6303 dnl --------------------
6304 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
6305 dnl won't, but they're still there.
6306 AC_DEFUN([CF_UNSIGNED_LITERALS],
6307 [
6308 AC_MSG_CHECKING([if unsigned literals are legal])
6309 AC_CACHE_VAL(cf_cv_unsigned_literals,[
6310         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
6311                 [cf_cv_unsigned_literals=yes],
6312                 [cf_cv_unsigned_literals=no])
6313         ])
6314 AC_MSG_RESULT($cf_cv_unsigned_literals)
6315 ])dnl
6316 dnl ---------------------------------------------------------------------------
6317 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
6318 dnl --------
6319 dnl Make an uppercase version of a variable
6320 dnl $1=uppercase($2)
6321 AC_DEFUN([CF_UPPER],
6322 [
6323 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6324 ])dnl
6325 dnl ---------------------------------------------------------------------------
6326 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
6327 dnl -----------
6328 dnl Check for multibyte support, and if not found, utf8 compatibility library
6329 AC_DEFUN([CF_UTF8_LIB],
6330 [
6331 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
6332         cf_save_LIBS="$LIBS"
6333         AC_TRY_LINK([
6334 #include <stdlib.h>],[putwc(0,0);],
6335         [cf_cv_utf8_lib=yes],
6336         [CF_FIND_LINKAGE([
6337 #include <libutf8.h>],[putwc(0,0);],utf8,
6338                 [cf_cv_utf8_lib=add-on],
6339                 [cf_cv_utf8_lib=no])
6340 ])])
6341
6342 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
6343 # ncurses/ncursesw:
6344 if test "$cf_cv_utf8_lib" = "add-on" ; then
6345         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
6346         CF_ADD_INCDIR($cf_cv_header_path_utf8)
6347         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
6348         CF_ADD_LIBS($cf_cv_library_file_utf8)
6349 fi
6350 ])dnl
6351 dnl ---------------------------------------------------------------------------
6352 dnl CF_VA_COPY version: 3 updated: 2012/10/06 11:17:15
6353 dnl ----------
6354 dnl check for va_copy, part of stdarg.h
6355 dnl Also, workaround for glibc's __va_copy, by checking for both.
6356 AC_DEFUN([CF_VA_COPY],[
6357 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
6358 AC_TRY_LINK([
6359 #include <stdarg.h>
6360 ],[
6361         static va_list dst;
6362         static va_list src;
6363         va_copy(dst, src)],
6364         cf_cv_have_va_copy=yes,
6365         cf_cv_have_va_copy=no)])
6366
6367 test "$cf_cv_have_va_copy" = yes && AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
6368
6369 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
6370 AC_TRY_LINK([
6371 #include <stdarg.h>
6372 ],[
6373         static va_list dst;
6374         static va_list src;
6375         __va_copy(dst, src)],
6376         cf_cv_have___va_copy=yes,
6377         cf_cv_have___va_copy=no)])
6378
6379 test "$cf_cv_have___va_copy" = yes && AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
6380 ])
6381 dnl ---------------------------------------------------------------------------
6382 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
6383 dnl ----------
6384 dnl Use AC_VERBOSE w/o the warnings
6385 AC_DEFUN([CF_VERBOSE],
6386 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
6387 CF_MSG_LOG([$1])
6388 ])dnl
6389 dnl ---------------------------------------------------------------------------
6390 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
6391 dnl -------------
6392 dnl Check if type wide-character type $1 is declared, and if so, which header
6393 dnl file is needed.  The second parameter is used to set a shell variable when
6394 dnl the type is not found.  The first parameter sets a shell variable for the
6395 dnl opposite sense.
6396 AC_DEFUN([CF_WCHAR_TYPE],
6397 [
6398 # This is needed on Tru64 5.0 to declare $1
6399 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
6400 AC_TRY_COMPILE([
6401 #include <stdlib.h>
6402 #include <stdarg.h>
6403 #include <stdio.h>
6404 #ifdef HAVE_LIBUTF8_H
6405 #include <libutf8.h>
6406 #endif],
6407         [$1 state],
6408         [cf_cv_$1=no],
6409         [AC_TRY_COMPILE([
6410 #include <stdlib.h>
6411 #include <stdarg.h>
6412 #include <stdio.h>
6413 #include <wchar.h>
6414 #ifdef HAVE_LIBUTF8_H
6415 #include <libutf8.h>
6416 #endif],
6417         [$1 value],
6418         [cf_cv_$1=yes],
6419         [cf_cv_$1=unknown])])])
6420
6421 if test "$cf_cv_$1" = yes ; then
6422         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
6423         NEED_WCHAR_H=1
6424 fi
6425
6426 ifelse([$2],,,[
6427 # if we do not find $1 in either place, use substitution to provide a fallback.
6428 if test "$cf_cv_$1" = unknown ; then
6429         $2=1
6430 fi
6431 ])
6432 ifelse($3,,,[
6433 # if we find $1 in either place, use substitution to provide a fallback.
6434 if test "$cf_cv_$1" != unknown ; then
6435         $3=1
6436 fi
6437 ])
6438 ])dnl
6439 dnl ---------------------------------------------------------------------------
6440 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
6441 dnl ---------------
6442 dnl Check for compiler-support for weak symbols.
6443 dnl This works with "recent" gcc.
6444 AC_DEFUN([CF_WEAK_SYMBOLS],[
6445 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
6446
6447 AC_TRY_COMPILE([
6448 #include <stdio.h>],
6449 [
6450 #if defined(__GNUC__)
6451 #  if defined __USE_ISOC99
6452 #    define _cat_pragma(exp)    _Pragma(#exp)
6453 #    define _weak_pragma(exp)   _cat_pragma(weak name)
6454 #  else
6455 #    define _weak_pragma(exp)
6456 #  endif
6457 #  define _declare(name)        __extension__ extern __typeof__(name) name
6458 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
6459 #endif
6460
6461 weak_symbol(fopen);
6462 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
6463 ])
6464 ])dnl
6465 dnl ---------------------------------------------------------------------------
6466 dnl CF_WITH_ABI_VERSION version: 1 updated: 2003/09/20 18:12:49
6467 dnl -------------------
6468 dnl Allow library's ABI to be overridden.  Generally this happens when a
6469 dnl packager has incremented the ABI past that used in the original package,
6470 dnl and wishes to keep doing this.
6471 dnl
6472 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
6473 dnl symbol.
6474 AC_DEFUN([CF_WITH_ABI_VERSION],[
6475 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
6476 AC_ARG_WITH(abi-version,
6477 [  --with-abi-version=XXX  override derived ABI version],
6478 [AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
6479  cf_cv_abi_version=$withval])
6480  CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
6481 ifelse($1,,,[
6482 $1_ABI=$cf_cv_abi_version
6483 ])
6484 ])dnl
6485 dnl ---------------------------------------------------------------------------
6486 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
6487 dnl --------------------
6488 dnl Command-line option to specify the Ada95 compiler.
6489 AC_DEFUN([CF_WITH_ADA_COMPILER],[
6490 AC_MSG_CHECKING(for ada-compiler)
6491 AC_ARG_WITH(ada-compiler,
6492         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
6493         [cf_ada_compiler=$withval],
6494         [cf_ada_compiler=gnatmake])
6495 AC_SUBST(cf_ada_compiler)
6496 AC_MSG_RESULT($cf_ada_compiler)
6497 ])dnl
6498 dnl ---------------------------------------------------------------------------
6499 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
6500 dnl -------------------
6501 dnl Command-line option to specify where Ada includes will install.
6502 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
6503 AC_MSG_CHECKING(for ada-include)
6504 CF_WITH_PATH(ada-include,
6505    [  --with-ada-include=DIR  Ada includes are in DIR],
6506    ADA_INCLUDE,
6507    PREFIX/share/ada/adainclude,
6508    [$]prefix/share/ada/adainclude)
6509 AC_SUBST(ADA_INCLUDE)
6510 AC_MSG_RESULT($ADA_INCLUDE)
6511 ])dnl
6512 dnl ---------------------------------------------------------------------------
6513 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
6514 dnl -------------------
6515 dnl Command-line option to specify where Ada objects will install.
6516 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
6517 AC_MSG_CHECKING(for ada-objects)
6518 CF_WITH_PATH(ada-objects,
6519    [  --with-ada-objects=DIR  Ada objects are in DIR],
6520    ADA_OBJECTS,
6521    PREFIX/lib/ada/adalib,
6522    [$]prefix/lib/ada/adalib)
6523 AC_SUBST(ADA_OBJECTS)
6524 AC_MSG_RESULT($ADA_OBJECTS)
6525 ])dnl
6526 dnl ---------------------------------------------------------------------------
6527 dnl CF_WITH_ADA_SHAREDLIB version: 2 updated: 2010/06/26 17:35:58
6528 dnl ---------------------
6529 dnl Command-line option to specify if an Ada95 shared-library should be built,
6530 dnl and optionally what its soname should be.
6531 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
6532 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
6533 AC_ARG_WITH(ada-sharedlib,
6534         [  --with-ada-sharedlib=XX build Ada95 shared-library],
6535         [with_ada_sharedlib=$withval],
6536         [with_ada_sharedlib=no])
6537 AC_MSG_RESULT($with_ada_sharedlib)
6538
6539 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
6540 MAKE_ADA_SHAREDLIB="#"
6541
6542 if test "x$with_ada_sharedlib" != xno
6543 then
6544         MAKE_ADA_SHAREDLIB=
6545         if test "x$with_ada_sharedlib" != xyes
6546         then
6547                 ADA_SHAREDLIB="$with_ada_sharedlib"
6548         fi
6549 fi
6550
6551 AC_SUBST(ADA_SHAREDLIB)
6552 AC_SUBST(MAKE_ADA_SHAREDLIB)
6553 ])dnl
6554 dnl ---------------------------------------------------------------------------
6555 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
6556 dnl ----------------
6557 dnl Configure-option for dbmalloc.  The optional parameter is used to override
6558 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6559 AC_DEFUN([CF_WITH_DBMALLOC],[
6560 CF_NO_LEAKS_OPTION(dbmalloc,
6561         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
6562         [USE_DBMALLOC])
6563
6564 if test "$with_dbmalloc" = yes ; then
6565         AC_CHECK_HEADER(dbmalloc.h,
6566                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
6567 fi
6568 ])dnl
6569 dnl ---------------------------------------------------------------------------
6570 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
6571 dnl ---------------
6572 dnl Configure-option for dmalloc.  The optional parameter is used to override
6573 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6574 AC_DEFUN([CF_WITH_DMALLOC],[
6575 CF_NO_LEAKS_OPTION(dmalloc,
6576         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
6577         [USE_DMALLOC])
6578
6579 if test "$with_dmalloc" = yes ; then
6580         AC_CHECK_HEADER(dmalloc.h,
6581                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
6582 fi
6583 ])dnl
6584 dnl ---------------------------------------------------------------------------
6585 dnl CF_WITH_GPM version: 8 updated: 2012/10/06 17:56:13
6586 dnl -----------
6587 dnl
6588 dnl The option parameter (if neither yes/no) is assumed to be the name of
6589 dnl the gpm library, e.g., for dynamic loading.
6590 AC_DEFUN([CF_WITH_GPM],
6591 [
6592 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
6593 AC_ARG_WITH(gpm,
6594         [  --with-gpm              use Alessandro Rubini's GPM library],
6595         [with_gpm=$withval],
6596         [with_gpm=maybe])
6597 AC_MSG_RESULT($with_gpm)
6598
6599 if test "$with_gpm" != no ; then
6600         AC_CHECK_HEADER(gpm.h,[
6601                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
6602                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
6603                         CF_VERBOSE(assuming we really have GPM library)
6604                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
6605                 else
6606                         AC_CHECK_LIB(gpm,Gpm_Open,[:],[
6607                                 AC_MSG_ERROR(Cannot link with GPM library)
6608                 fi
6609                 with_gpm=yes
6610                 ])
6611         ],[
6612                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
6613                 with_gpm=no
6614         ])
6615 fi
6616 ])
6617 dnl ---------------------------------------------------------------------------
6618 dnl CF_WITH_LIBTOOL version: 28 updated: 2011/07/02 15:40:32
6619 dnl ---------------
6620 dnl Provide a configure option to incorporate libtool.  Define several useful
6621 dnl symbols for the makefile rules.
6622 dnl
6623 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
6624 dnl macros from libtool.m4 which is in the aclocal directory of automake.
6625 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
6626 dnl But that still does not work properly since the macro is expanded outside
6627 dnl the CF_WITH_LIBTOOL macro:
6628 dnl
6629 dnl     #!/bin/sh
6630 dnl     ACLOCAL=`aclocal --print-ac-dir`
6631 dnl     if test -z "$ACLOCAL" ; then
6632 dnl             echo cannot find aclocal directory
6633 dnl             exit 1
6634 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
6635 dnl             echo cannot find libtool.m4 file
6636 dnl             exit 1
6637 dnl     fi
6638 dnl
6639 dnl     LOCAL=aclocal.m4
6640 dnl     ORIG=aclocal.m4.orig
6641 dnl
6642 dnl     trap "mv $ORIG $LOCAL" 0 1 2 5 15
6643 dnl     rm -f $ORIG
6644 dnl     mv $LOCAL $ORIG
6645 dnl
6646 dnl     # sed the LIBTOOL= assignment to omit the current directory?
6647 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
6648 dnl     cat $ORIG >>$LOCAL
6649 dnl
6650 dnl     autoconf-257 $*
6651 dnl
6652 AC_DEFUN([CF_WITH_LIBTOOL],
6653 [
6654 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
6655 ifdef([AC_PROG_LIBTOOL],,[
6656 LIBTOOL=
6657 ])
6658 # common library maintenance symbols that are convenient for libtool scripts:
6659 LIB_CREATE='${AR} -cr'
6660 LIB_OBJECT='${OBJECTS}'
6661 LIB_SUFFIX=.a
6662 LIB_PREP="$RANLIB"
6663
6664 # symbols used to prop libtool up to enable it to determine what it should be
6665 # doing:
6666 LIB_CLEAN=
6667 LIB_COMPILE=
6668 LIB_LINK='${CC}'
6669 LIB_INSTALL=
6670 LIB_UNINSTALL=
6671
6672 AC_MSG_CHECKING(if you want to build libraries with libtool)
6673 AC_ARG_WITH(libtool,
6674         [  --with-libtool          generate libraries with libtool],
6675         [with_libtool=$withval],
6676         [with_libtool=no])
6677 AC_MSG_RESULT($with_libtool)
6678 if test "$with_libtool" != "no"; then
6679 ifdef([AC_PROG_LIBTOOL],[
6680         # missing_content_AC_PROG_LIBTOOL{{
6681         AC_PROG_LIBTOOL
6682         # missing_content_AC_PROG_LIBTOOL}}
6683 ],[
6684         if test "$with_libtool" != "yes" ; then
6685                 CF_PATH_SYNTAX(with_libtool)
6686                 LIBTOOL=$with_libtool
6687         else
6688                 AC_PATH_PROG(LIBTOOL,libtool)
6689         fi
6690         if test -z "$LIBTOOL" ; then
6691                 AC_MSG_ERROR(Cannot find libtool)
6692         fi
6693 ])dnl
6694         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${DESTDIR}${libdir} ${LIBTOOL_VERSION} `cut -f1 ${srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
6695         LIB_OBJECT='${OBJECTS:.o=.lo}'
6696         LIB_SUFFIX=.la
6697         LIB_CLEAN='${LIBTOOL} --mode=clean'
6698         LIB_COMPILE='${LIBTOOL} --mode=compile'
6699         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
6700         LIB_INSTALL='${LIBTOOL} --mode=install'
6701         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
6702         LIB_PREP=:
6703
6704         # Show the version of libtool
6705         AC_MSG_CHECKING(version of libtool)
6706
6707         # Save the version in a cache variable - this is not entirely a good
6708         # thing, but the version string from libtool is very ugly, and for
6709         # bug reports it might be useful to have the original string. "("
6710         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
6711         AC_MSG_RESULT($cf_cv_libtool_version)
6712         if test -z "$cf_cv_libtool_version" ; then
6713                 AC_MSG_ERROR(This is not GNU libtool)
6714         fi
6715
6716         # special hack to add -no-undefined (which libtool should do for itself)
6717         LT_UNDEF=
6718         case "$cf_cv_system_name" in #(vi
6719         cygwin*|mingw32*|uwin*|aix[[4-7]]) #(vi
6720                 LT_UNDEF=-no-undefined
6721                 ;;
6722         esac
6723         AC_SUBST([LT_UNDEF])
6724
6725         # special hack to add --tag option for C++ compiler
6726         case $cf_cv_libtool_version in #(vi
6727         1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*) #(vi
6728                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
6729                 LIBTOOL="$LIBTOOL --tag=CC"
6730                 ;;
6731         *)
6732                 LIBTOOL_CXX="$LIBTOOL"
6733                 ;;
6734         esac
6735 else
6736         LIBTOOL=""
6737         LIBTOOL_CXX=""
6738 fi
6739
6740 test -z "$LIBTOOL" && ECHO_LT=
6741
6742 AC_SUBST(LIBTOOL)
6743 AC_SUBST(LIBTOOL_CXX)
6744 AC_SUBST(LIBTOOL_OPTS)
6745
6746 AC_SUBST(LIB_CREATE)
6747 AC_SUBST(LIB_OBJECT)
6748 AC_SUBST(LIB_SUFFIX)
6749 AC_SUBST(LIB_PREP)
6750
6751 AC_SUBST(LIB_CLEAN)
6752 AC_SUBST(LIB_COMPILE)
6753 AC_SUBST(LIB_LINK)
6754 AC_SUBST(LIB_INSTALL)
6755 AC_SUBST(LIB_UNINSTALL)
6756
6757 ])dnl
6758 dnl ---------------------------------------------------------------------------
6759 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
6760 dnl ------------------
6761 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
6762 dnl "lib" prefix, e.g., because it used the dll naming convention.
6763 dnl
6764 dnl $1 = variable to set
6765 AC_DEFUN([CF_WITH_LIB_PREFIX],
6766 [
6767 AC_MSG_CHECKING(if you want to have a library-prefix)
6768 AC_ARG_WITH(lib-prefix,
6769         [  --with-lib-prefix       override library-prefix],
6770         [with_lib_prefix=$withval],
6771         [with_lib_prefix=auto])
6772 AC_MSG_RESULT($with_lib_prefix)
6773
6774 if test $with_lib_prefix = auto
6775 then
6776         CF_LIB_PREFIX($1)
6777 elif test $with_lib_prefix = no
6778 then
6779         LIB_PREFIX=
6780 else
6781         LIB_PREFIX=$with_lib_prefix
6782 fi
6783 ])dnl
6784 dnl ---------------------------------------------------------------------------
6785 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
6786 dnl ------------
6787 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
6788 dnl defaulting to yes/no.
6789 dnl
6790 dnl $1 = option name
6791 dnl $2 = help-text
6792 dnl $3 = environment variable to set
6793 dnl $4 = default value, shown in the help-message, must be a constant
6794 dnl $5 = default value, if it's an expression & cannot be in the help-message
6795 dnl
6796 AC_DEFUN([CF_WITH_PATH],
6797 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
6798 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
6799 if ifelse([$5],,true,[test -n "$5"]) ; then
6800 CF_PATH_SYNTAX(withval)
6801 fi
6802 eval $3="$withval"
6803 AC_SUBST($3)dnl
6804 ])dnl
6805 dnl ---------------------------------------------------------------------------
6806 dnl CF_WITH_PATHLIST version: 9 updated: 2012/10/18 05:05:24
6807 dnl ----------------
6808 dnl Process an option specifying a list of colon-separated paths.
6809 dnl
6810 dnl $1 = option name
6811 dnl $2 = help-text
6812 dnl $3 = environment variable to set
6813 dnl $4 = default value, shown in the help-message, must be a constant
6814 dnl $5 = default value, if it's an expression & cannot be in the help-message
6815 dnl $6 = flag to tell if we want to define or substitute
6816 dnl
6817 AC_DEFUN([CF_WITH_PATHLIST],[
6818 AC_REQUIRE([CF_PATHSEP])
6819 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
6820 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
6821
6822 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
6823 cf_dst_path=
6824 for cf_src_path in $withval
6825 do
6826   CF_PATH_SYNTAX(cf_src_path)
6827   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
6828   cf_dst_path="${cf_dst_path}${cf_src_path}"
6829 done
6830 IFS="$ac_save_ifs"
6831
6832 ifelse($6,define,[
6833 # Strip single quotes from the value, e.g., when it was supplied as a literal
6834 # for $4 or $5.
6835 case $cf_dst_path in #(vi
6836 \'*)
6837   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
6838   ;;
6839 esac
6840 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
6841 ])
6842
6843 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
6844 # so we have to check/work around.  We do prefer the result of "eval"...
6845 eval cf_dst_eval="$cf_dst_path"
6846 case "x$cf_dst_eval" in #(vi
6847 xNONE*) #(vi
6848         $3=$cf_dst_path
6849         ;;
6850 *)
6851         $3="$cf_dst_eval"
6852         ;;
6853 esac
6854 AC_SUBST($3)dnl
6855
6856 ])dnl
6857 dnl ---------------------------------------------------------------------------
6858 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 2 updated: 2011/12/10 18:58:47
6859 dnl -------------------------
6860 dnl Allow the choice of the pkg-config library directory to be overridden.
6861 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
6862 if test "$PKG_CONFIG" != none ; then
6863         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
6864         AC_ARG_WITH(pkg-config-libdir,
6865                 [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
6866                 [PKG_CONFIG_LIBDIR=$withval],
6867                 [PKG_CONFIG_LIBDIR=yes])
6868
6869         case x$PKG_CONFIG_LIBDIR in #(vi
6870         x/*) #(vi
6871                 ;;
6872         xyes) #(vi
6873                 # look for the library directory using the same prefix as the executable
6874                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
6875                 case x`(arch) 2>/dev/null` in #(vi
6876                 *64) #(vi
6877                         for cf_config in $cf_path/share $cf_path/lib64 $cf_path/lib32 $cf_path/lib
6878                         do
6879                                 if test -d $cf_config/pkgconfig
6880                                 then
6881                                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
6882                                         break
6883                                 fi
6884                         done
6885                         ;;
6886                 *)
6887                         PKG_CONFIG_LIBDIR=$cf_path/lib/pkgconfig
6888                         ;;
6889                 esac
6890                 ;;
6891         *)
6892                 ;;
6893         esac
6894
6895         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
6896 fi
6897
6898 AC_SUBST(PKG_CONFIG_LIBDIR)
6899 ])dnl
6900 dnl ---------------------------------------------------------------------------
6901 dnl CF_WITH_PTHREAD version: 6 updated: 2012/10/06 17:41:51
6902 dnl ---------------
6903 dnl Check for POSIX thread library.
6904 AC_DEFUN([CF_WITH_PTHREAD],
6905 [
6906 AC_MSG_CHECKING(if you want to link with the pthread library)
6907 AC_ARG_WITH(pthread,
6908     [  --with-pthread          use POSIX thread library],
6909     [with_pthread=$withval],
6910     [with_pthread=no])
6911 AC_MSG_RESULT($with_pthread)
6912
6913 if test "$with_pthread" != no ; then
6914     AC_CHECK_HEADER(pthread.h,[
6915         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
6916
6917         for cf_lib_pthread in pthread c_r
6918         do
6919             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
6920             cf_save_LIBS="$LIBS"
6921             CF_ADD_LIB($cf_lib_pthread)
6922             AC_TRY_LINK([
6923 #include <pthread.h>
6924 ],[
6925                 int rc = pthread_create(0,0,0,0);
6926                 int r2 = pthread_mutexattr_settype(0, 0);
6927 ],[with_pthread=yes],[with_pthread=no])
6928             LIBS="$cf_save_LIBS"
6929             AC_MSG_RESULT($with_pthread)
6930             test "$with_pthread" = yes && break
6931         done
6932
6933         if test "$with_pthread" = yes ; then
6934             CF_ADD_LIB($cf_lib_pthread)
6935             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
6936         else
6937             AC_MSG_ERROR(Cannot link with pthread library)
6938         fi
6939     ])
6940 fi
6941 ])
6942 dnl ---------------------------------------------------------------------------
6943 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
6944 dnl -------------------
6945 dnl Allow library's release-version to be overridden.  Generally this happens when a
6946 dnl packager has incremented the release-version past that used in the original package,
6947 dnl and wishes to keep doing this.
6948 dnl
6949 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
6950 dnl and {package}_MINOR symbols
6951 dnl symbol.
6952 AC_DEFUN([CF_WITH_REL_VERSION],[
6953 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
6954 AC_ARG_WITH(rel-version,
6955 [  --with-rel-version=XXX  override derived release version],
6956 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
6957  cf_cv_rel_version=$withval])
6958 ifelse($1,,[
6959  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
6960 ],[
6961  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
6962  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
6963  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
6964  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
6965 ])
6966 ])dnl
6967 dnl ---------------------------------------------------------------------------
6968 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
6969 dnl ----------------
6970 dnl If we can compile with sysmouse, make it available unless it is not wanted.
6971 AC_DEFUN([CF_WITH_SYSMOUSE],[
6972 # not everyone has "test -c"
6973 if test -c /dev/sysmouse 2>/dev/null ; then
6974 AC_MSG_CHECKING(if you want to use sysmouse)
6975 AC_ARG_WITH(sysmouse,
6976         [  --with-sysmouse         use sysmouse (FreeBSD console)],
6977         [cf_with_sysmouse=$withval],
6978         [cf_with_sysmouse=maybe])
6979         if test "$cf_with_sysmouse" != no ; then
6980         AC_TRY_COMPILE([
6981 #include <osreldate.h>
6982 #if (__FreeBSD_version >= 400017)
6983 #include <sys/consio.h>
6984 #include <sys/fbio.h>
6985 #else
6986 #include <machine/console.h>
6987 #endif
6988 ],[
6989         struct mouse_info the_mouse;
6990         ioctl(0, CONS_MOUSECTL, &the_mouse);
6991 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
6992         fi
6993 AC_MSG_RESULT($cf_with_sysmouse)
6994 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
6995 fi
6996 ])dnl
6997 dnl ---------------------------------------------------------------------------
6998 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
6999 dnl ---------------
7000 dnl For testing, override the derived host system-type which is used to decide
7001 dnl things such as the linker commands used to build shared libraries.  This is
7002 dnl normally chosen automatically based on the type of system which you are
7003 dnl building on.  We use it for testing the configure script.
7004 dnl
7005 dnl This is different from the --host option: it is used only for testing parts
7006 dnl of the configure script which would not be reachable with --host since that
7007 dnl relies on the build environment being real, rather than mocked up.
7008 AC_DEFUN([CF_WITH_SYSTYPE],[
7009 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
7010 AC_ARG_WITH(system-type,
7011         [  --with-system-type=XXX  test: override derived host system-type],
7012 [AC_MSG_WARN(overriding system type to $withval)
7013         cf_cv_system_name=$withval
7014         host_os=$withval
7015 ])
7016 ])dnl
7017 dnl ---------------------------------------------------------------------------
7018 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
7019 dnl ----------------
7020 AC_DEFUN([CF_WITH_VALGRIND],[
7021 CF_NO_LEAKS_OPTION(valgrind,
7022         [  --with-valgrind         test: use valgrind],
7023         [USE_VALGRIND])
7024 ])dnl
7025 dnl ---------------------------------------------------------------------------
7026 dnl CF_XOPEN_SOURCE version: 43 updated: 2013/02/10 10:41:05
7027 dnl ---------------
7028 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
7029 dnl or adapt to the vendor's definitions to get equivalent functionality,
7030 dnl without losing the common non-POSIX features.
7031 dnl
7032 dnl Parameters:
7033 dnl     $1 is the nominal value for _XOPEN_SOURCE
7034 dnl     $2 is the nominal value for _POSIX_C_SOURCE
7035 AC_DEFUN([CF_XOPEN_SOURCE],[
7036 AC_REQUIRE([AC_CANONICAL_HOST])
7037
7038 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
7039 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
7040 cf_xopen_source=
7041
7042 case $host_os in #(vi
7043 aix[[4-7]]*) #(vi
7044         cf_xopen_source="-D_ALL_SOURCE"
7045         ;;
7046 cygwin) #(vi
7047         cf_XOPEN_SOURCE=600
7048         ;;
7049 darwin[[0-8]].*) #(vi
7050         cf_xopen_source="-D_APPLE_C_SOURCE"
7051         ;;
7052 darwin*) #(vi
7053         cf_xopen_source="-D_DARWIN_C_SOURCE"
7054         cf_XOPEN_SOURCE=
7055         ;;
7056 freebsd*|dragonfly*) #(vi
7057         # 5.x headers associate
7058         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
7059         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
7060         cf_POSIX_C_SOURCE=200112L
7061         cf_XOPEN_SOURCE=600
7062         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
7063         ;;
7064 hpux11*) #(vi
7065         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
7066         ;;
7067 hpux*) #(vi
7068         cf_xopen_source="-D_HPUX_SOURCE"
7069         ;;
7070 irix[[56]].*) #(vi
7071         cf_xopen_source="-D_SGI_SOURCE"
7072         cf_XOPEN_SOURCE=
7073         ;;
7074 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
7075         CF_GNU_SOURCE
7076         ;;
7077 mirbsd*) #(vi
7078         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
7079         cf_XOPEN_SOURCE=
7080         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7081         ;;
7082 netbsd*) #(vi
7083         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
7084         ;;
7085 openbsd[[4-9]]*) #(vi
7086         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
7087         cf_xopen_source="-D_BSD_SOURCE"
7088         cf_XOPEN_SOURCE=600
7089         ;;
7090 openbsd*) #(vi
7091         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
7092         ;;
7093 osf[[45]]*) #(vi
7094         cf_xopen_source="-D_OSF_SOURCE"
7095         ;;
7096 nto-qnx*) #(vi
7097         cf_xopen_source="-D_QNX_SOURCE"
7098         ;;
7099 sco*) #(vi
7100         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
7101         ;;
7102 solaris2.*) #(vi
7103         cf_xopen_source="-D__EXTENSIONS__"
7104         ;;
7105 *)
7106         CF_TRY_XOPEN_SOURCE
7107         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7108         ;;
7109 esac
7110
7111 if test -n "$cf_xopen_source" ; then
7112         CF_ADD_CFLAGS($cf_xopen_source)
7113 fi
7114
7115 dnl In anything but the default case, we may have system-specific setting
7116 dnl which is still not guaranteed to provide all of the entrypoints that
7117 dnl _XOPEN_SOURCE would yield.
7118 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
7119         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
7120         AC_TRY_COMPILE([#include <stdlib.h>],[
7121 #ifndef _XOPEN_SOURCE
7122 make an error
7123 #endif],
7124         [cf_XOPEN_SOURCE_set=yes],
7125         [cf_XOPEN_SOURCE_set=no])
7126         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
7127         if test $cf_XOPEN_SOURCE_set = yes
7128         then
7129                 AC_TRY_COMPILE([#include <stdlib.h>],[
7130 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
7131 make an error
7132 #endif],
7133                 [cf_XOPEN_SOURCE_set_ok=yes],
7134                 [cf_XOPEN_SOURCE_set_ok=no])
7135                 if test $cf_XOPEN_SOURCE_set_ok = no
7136                 then
7137                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
7138                 fi
7139         else
7140                 CF_TRY_XOPEN_SOURCE
7141         fi
7142 fi
7143 ])