aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2019,2020 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: aclocal.m4,v 1.938 2020/10/31 19:51:56 tom Exp $
  33 dnl Macros used in NCURSES auto-configuration script.
  34 dnl
  35 dnl These macros are maintained separately from NCURSES.  The copyright on
  36 dnl this file applies to the aggregation of macros and does not affect use of
  37 dnl these macros in other applications.
  38 dnl
  39 dnl See these pages for additional information:
  40 dnl             https://invisible-island.net/autoconf/
  41 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  42 dnl
  43 dnl ---------------------------------------------------------------------------
  44 dnl ---------------------------------------------------------------------------
  45 dnl AM_LANGINFO_CODESET version: 5 updated: 2020/03/10 18:53:47
  46 dnl -------------------
  47 dnl Inserted as requested by gettext 0.10.40
  48 dnl File from /usr/share/aclocal
  49 dnl codeset.m4
  50 dnl ====================
  51 dnl serial AM1
  52 dnl
  53 dnl From Bruno Haible.
  54 AC_DEFUN([AM_LANGINFO_CODESET],
  55 [
  56 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  57         [AC_TRY_LINK([#include <langinfo.h>],
  58         [char* cs = nl_langinfo(CODESET); (void)cs],
  59         am_cv_langinfo_codeset=yes,
  60         am_cv_langinfo_codeset=no)
  61         ])
  62         if test $am_cv_langinfo_codeset = yes; then
  63                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  64                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  65         fi
  66 ])dnl
  67 dnl ---------------------------------------------------------------------------
  68 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
  69 dnl ---------------
  70 dnl Provide configure-script defaults for different ncurses ABIs.
  71 AC_DEFUN([CF_ABI_DEFAULTS],[
  72 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  73 case x$cf_cv_abi_version in
  74 (x[[6789]])
  75         cf_dft_ext_colors=yes
  76         cf_dft_ext_const=yes
  77         cf_dft_ext_mouse=yes
  78         cf_dft_ext_putwin=yes
  79         cf_dft_ext_spfuncs=yes
  80         cf_dft_filter_syms=yes
  81         cf_dft_chtype=uint32_t
  82         cf_dft_mmask_t=uint32_t
  83         cf_dft_interop=yes
  84         cf_dft_tparm_arg=intptr_t
  85         cf_dft_with_lp64=yes
  86         ;;
  87 (*)
  88         cf_dft_ext_colors=no
  89         cf_dft_ext_const=no
  90         cf_dft_ext_mouse=no
  91         cf_dft_ext_putwin=no
  92         cf_dft_ext_spfuncs=no
  93         cf_dft_filter_syms=no
  94         cf_dft_chtype=auto
  95         cf_dft_mmask_t=auto
  96         cf_dft_interop=no
  97         cf_dft_tparm_arg=long
  98         cf_dft_with_lp64=no
  99         ;;
 100 esac
 101 ])dnl
 102 dnl ---------------------------------------------------------------------------
 103 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 104 dnl ------------------
 105 dnl Conditionally generate script according to whether we're using a given autoconf.
 106 dnl
 107 dnl $1 = version to compare against
 108 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 109 dnl $3 = code to use if AC_ACVERSION is older than $1.
 110 define([CF_ACVERSION_CHECK],
 111 [
 112 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 113 ifdef([m4_version_compare],
 114 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 115 [CF_ACVERSION_COMPARE(
 116 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 117 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 118 dnl ---------------------------------------------------------------------------
 119 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 120 dnl --------------------
 121 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 122 dnl                      MAJOR2, MINOR2, TERNARY2,
 123 dnl                      PRINTABLE2, not FOUND, FOUND)
 124 define([CF_ACVERSION_COMPARE],
 125 [ifelse(builtin([eval], [$2 < $5]), 1,
 126 [ifelse([$8], , ,[$8])],
 127 [ifelse([$9], , ,[$9])])])dnl
 128 dnl ---------------------------------------------------------------------------
 129 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 130 dnl -------------------
 131 dnl Construct the list of include-options for the C programs in the Ada95
 132 dnl binding.
 133 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 134 [
 135 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 136 if test "$srcdir" != "."; then
 137         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 138 fi
 139 if test "$GCC" != yes; then
 140         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 141 elif test "$includedir" != "/usr/include"; then
 142         if test "$includedir" = '${prefix}/include' ; then
 143                 if test x$prefix != x/usr ; then
 144                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 145                 fi
 146         else
 147                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 148         fi
 149 fi
 150 AC_SUBST(ACPPFLAGS)
 151 ])dnl
 152 dnl ---------------------------------------------------------------------------
 153 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 154 dnl ---------------
 155 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 156 AC_DEFUN([CF_ADD_ADAFLAGS],[
 157         ADAFLAGS="$ADAFLAGS $1"
 158         AC_SUBST(ADAFLAGS)
 159 ])dnl
 160 dnl ---------------------------------------------------------------------------
 161 dnl CF_ADD_CFLAGS version: 14 updated: 2020/04/04 16:16:13
 162 dnl -------------
 163 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 164 dnl $1 = flags to add
 165 dnl $2 = if given makes this macro verbose.
 166 dnl
 167 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 168 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 169 dnl confused by the quotes (which require backslashes to keep them usable).
 170 AC_DEFUN([CF_ADD_CFLAGS],
 171 [
 172 cf_fix_cppflags=no
 173 cf_new_cflags=
 174 cf_new_cppflags=
 175 cf_new_extra_cppflags=
 176
 177 for cf_add_cflags in $1
 178 do
 179 case $cf_fix_cppflags in
 180 (no)
 181         case $cf_add_cflags in
 182         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 183                 case $cf_add_cflags in
 184                 (-D*)
 185                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 186
 187                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 188                                 && test -z "${cf_tst_cflags}" \
 189                                 && cf_fix_cppflags=yes
 190
 191                         if test $cf_fix_cppflags = yes ; then
 192                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 193                                 continue
 194                         elif test "${cf_tst_cflags}" = "\"'" ; then
 195                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 196                                 continue
 197                         fi
 198                         ;;
 199                 esac
 200                 case "$CPPFLAGS" in
 201                 (*$cf_add_cflags)
 202                         ;;
 203                 (*)
 204                         case $cf_add_cflags in
 205                         (-D*)
 206                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 207                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 208                                 ;;
 209                         esac
 210                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 211                         ;;
 212                 esac
 213                 ;;
 214         (*)
 215                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 216                 ;;
 217         esac
 218         ;;
 219 (yes)
 220         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 221
 222         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 223
 224         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 225                 && test -z "${cf_tst_cflags}" \
 226                 && cf_fix_cppflags=no
 227         ;;
 228 esac
 229 done
 230
 231 if test -n "$cf_new_cflags" ; then
 232         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 233         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 234 fi
 235
 236 if test -n "$cf_new_cppflags" ; then
 237         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 238         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 239 fi
 240
 241 if test -n "$cf_new_extra_cppflags" ; then
 242         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 243         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 244 fi
 245
 246 AC_SUBST(EXTRA_CPPFLAGS)
 247
 248 ])dnl
 249 dnl ---------------------------------------------------------------------------
 250 dnl CF_ADD_CXXFLAGS version: 1 updated: 2020/04/04 16:16:13
 251 dnl ---------------
 252 dnl Copy non-preprocessor flags to $CXXFLAGS, preprocessor flags to $CPPFLAGS
 253 dnl The second parameter if given makes this macro verbose.
 254 dnl
 255 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 256 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 257 dnl confused by the quotes (which require backslashes to keep them usable).
 258 AC_DEFUN([CF_ADD_CXXFLAGS],
 259 [
 260 cf_save_CXXFLAGS="$CFLAGS"
 261 CFLAGS="$CXXFLAGS"
 262 CF_ADD_CFLAGS($1 ifelse($2,,,[,$2]))
 263 CXXFLAGS="$CFLAGS"
 264 CFLAGS="$cf_save_CXXFLAGS"
 265 ])dnl
 266 dnl ---------------------------------------------------------------------------
 267 dnl CF_ADD_INCDIR version: 15 updated: 2018/06/20 20:23:13
 268 dnl -------------
 269 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 270 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 271 dnl but old versions (and some misinstalled ones) need that.  To make things
 272 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 273 dnl the include-path).
 274 AC_DEFUN([CF_ADD_INCDIR],
 275 [
 276 if test -n "$1" ; then
 277   for cf_add_incdir in $1
 278   do
 279         while test $cf_add_incdir != /usr/include
 280         do
 281           if test -d $cf_add_incdir
 282           then
 283                 cf_have_incdir=no
 284                 if test -n "$CFLAGS$CPPFLAGS" ; then
 285                   # a loop is needed to ensure we can add subdirs of existing dirs
 286                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 287                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 288                           cf_have_incdir=yes; break
 289                         fi
 290                   done
 291                 fi
 292
 293                 if test "$cf_have_incdir" = no ; then
 294                   if test "$cf_add_incdir" = /usr/local/include ; then
 295                         if test "$GCC" = yes
 296                         then
 297                           cf_save_CPPFLAGS=$CPPFLAGS
 298                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 299                           AC_TRY_COMPILE([#include <stdio.h>],
 300                                   [printf("Hello")],
 301                                   [],
 302                                   [cf_have_incdir=yes])
 303                           CPPFLAGS=$cf_save_CPPFLAGS
 304                         fi
 305                   fi
 306                 fi
 307
 308                 if test "$cf_have_incdir" = no ; then
 309                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 310                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 311
 312                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 313                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 314                   cf_add_incdir="$cf_top_incdir"
 315                 else
 316                   break
 317                 fi
 318           else
 319                 break
 320           fi
 321         done
 322   done
 323 fi
 324 ])dnl
 325 dnl ---------------------------------------------------------------------------
 326 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 327 dnl ----------
 328 dnl Add a library, used to enforce consistency.
 329 dnl
 330 dnl $1 = library to add, without the "-l"
 331 dnl $2 = variable to update (default $LIBS)
 332 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 333 dnl ---------------------------------------------------------------------------
 334 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 335 dnl -------------
 336 dnl     Adds to the library-path
 337 dnl
 338 dnl     Some machines have trouble with multiple -L options.
 339 dnl
 340 dnl $1 is the (list of) directory(s) to add
 341 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 342 dnl
 343 AC_DEFUN([CF_ADD_LIBDIR],
 344 [
 345 if test -n "$1" ; then
 346         for cf_add_libdir in $1
 347         do
 348                 if test $cf_add_libdir = /usr/lib ; then
 349                         :
 350                 elif test -d $cf_add_libdir
 351                 then
 352                         cf_have_libdir=no
 353                         if test -n "$LDFLAGS$LIBS" ; then
 354                                 # a loop is needed to ensure we can add subdirs of existing dirs
 355                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 356                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 357                                                 cf_have_libdir=yes; break
 358                                         fi
 359                                 done
 360                         fi
 361                         if test "$cf_have_libdir" = no ; then
 362                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 363                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 364                         fi
 365                 fi
 366         done
 367 fi
 368 ])dnl
 369 dnl ---------------------------------------------------------------------------
 370 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
 371 dnl -----------
 372 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 373 dnl prepended to an existing list, since their dependencies are assumed to
 374 dnl already exist in the list.
 375 dnl
 376 dnl $1 = libraries to add, with the "-l", etc.
 377 dnl $2 = variable to update (default $LIBS)
 378 AC_DEFUN([CF_ADD_LIBS],[
 379 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
 380 # reverse order
 381 cf_add_0lib=
 382 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
 383 # filter duplicates
 384 for cf_add_1lib in $cf_add_0lib; do
 385         for cf_add_2lib in $cf_add_libs; do
 386                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
 387                         cf_add_1lib=
 388                         break
 389                 fi
 390         done
 391         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
 392 done
 393 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 394 ])dnl
 395 dnl ---------------------------------------------------------------------------
 396 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 397 dnl ------------------
 398 dnl Append to a search-list for a nonstandard header/lib-file
 399 dnl     $1 = the variable to return as result
 400 dnl     $2 = the package name
 401 dnl     $3 = the subdirectory, e.g., bin, include or lib
 402 dnl $4 = the directory under which we will test for subdirectories
 403 dnl $5 = a directory that we do not want $4 to match
 404 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 405 [
 406 test "x$4" != "x$5" && \
 407 test -d "$4" && \
 408 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 409         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 410         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 411         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 412         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 413         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 414         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 415 }
 416 ])dnl
 417 dnl ---------------------------------------------------------------------------
 418 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 419 dnl --------------
 420 dnl use this macro for appending text without introducing an extra blank at
 421 dnl the beginning
 422 define([CF_APPEND_TEXT],
 423 [
 424         test -n "[$]$1" && $1="[$]$1 "
 425         $1="[$]{$1}$2"
 426 ])dnl
 427 dnl ---------------------------------------------------------------------------
 428 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 429 dnl --------------
 430 dnl Allow user to disable a normally-on option.
 431 AC_DEFUN([CF_ARG_DISABLE],
 432 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 433 dnl ---------------------------------------------------------------------------
 434 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 435 dnl -------------
 436 dnl Allow user to enable a normally-off option.
 437 AC_DEFUN([CF_ARG_ENABLE],
 438 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 439 dnl ---------------------------------------------------------------------------
 440 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 441 dnl -------------
 442 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 443 dnl values.
 444 dnl
 445 dnl Parameters:
 446 dnl $1 = option name
 447 dnl $2 = help-string
 448 dnl $3 = action to perform if option is not default
 449 dnl $4 = action if perform if option is default
 450 dnl $5 = default option value (either 'yes' or 'no')
 451 AC_DEFUN([CF_ARG_OPTION],
 452 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 453         if test "$enableval" != "$5" ; then
 454 ifelse([$3],,[    :]dnl
 455 ,[    $3]) ifelse([$4],,,[
 456         else
 457                 $4])
 458         fi],[enableval=$5 ifelse([$4],,,[
 459         $4
 460 ])dnl
 461 ])])dnl
 462 dnl ---------------------------------------------------------------------------
 463 dnl CF_AR_FLAGS version: 7 updated: 2020/04/04 11:37:29
 464 dnl -----------
 465 dnl Check for suitable "ar" (archiver) options for updating an archive.
 466 dnl
 467 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 468 dnl as well as a workaround for breakage of make's archive rules by the GNU
 469 dnl binutils "ar" program.
 470 AC_DEFUN([CF_AR_FLAGS],[
 471 AC_REQUIRE([CF_PROG_AR])
 472
 473 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 474         case $cf_cv_system_name in
 475         (*-msvc*)
 476                 cf_cv_ar_flags=''
 477                 cat >mk_static_lib.sh <<-EOF
 478                 #!$SHELL
 479                 MSVC_BIN="[$]AR"
 480                 out="\[$]1"
 481                 shift
 482                 exec \[$]MSVC_BIN -out:"\[$]out" \[$]@
 483                 EOF
 484                 chmod +x mk_static_lib.sh
 485                 AR=`pwd`/mk_static_lib.sh
 486                 ;;
 487         (*)
 488                 cf_cv_ar_flags=unknown
 489                 for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 490                 do
 491
 492                         # check if $ARFLAGS already contains this choice
 493                         if test "x$ARFLAGS" != "x" ; then
 494                                 cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 495                                 if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 496                                         cf_cv_ar_flags=
 497                                         break
 498                                 fi
 499                         fi
 500
 501                         rm -f conftest.$ac_cv_objext
 502                         rm -f conftest.a
 503
 504                         cat >conftest.$ac_ext <<EOF
 505 #line __oline__ "configure"
 506 int     testdata[[3]] = { 123, 456, 789 };
 507 EOF
 508                         if AC_TRY_EVAL(ac_compile) ; then
 509                                 echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 510                                 $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 511                                 if test -f conftest.a ; then
 512                                         cf_cv_ar_flags=$cf_ar_flags
 513                                         break
 514                                 fi
 515                         else
 516                                 CF_VERBOSE(cannot compile test-program)
 517                                 break
 518                         fi
 519                 done
 520                 rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 521                 ;;
 522         esac
 523 ])
 524
 525 if test -n "$ARFLAGS" ; then
 526         if test -n "$cf_cv_ar_flags" ; then
 527                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 528         fi
 529 else
 530         ARFLAGS=$cf_cv_ar_flags
 531 fi
 532
 533 AC_SUBST(ARFLAGS)
 534 ])
 535 dnl ---------------------------------------------------------------------------
 536 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 537 dnl -----------------
 538 dnl Check if awk can handle big strings using printf.  Some older versions of
 539 dnl awk choke on large strings passed via "%s".
 540 dnl
 541 dnl $1 = desired string size
 542 dnl $2 = variable to set with result
 543 AC_DEFUN([CF_AWK_BIG_PRINTF],
 544 [
 545         case x$AWK in
 546         (x)
 547                 eval $2=no
 548                 ;;
 549         (*)
 550                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 551                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 552                         eval $2=yes
 553                 else
 554                         eval $2=no
 555                 fi
 556                 ;;
 557         esac
 558 ])dnl
 559 dnl ---------------------------------------------------------------------------
 560 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 561 dnl ------------
 562 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 563 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 564 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 565 dnl
 566 dnl Treat the configuration-variable specially here, since we're directly
 567 dnl substituting its value (i.e., 1/0).
 568 dnl
 569 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 570 AC_DEFUN([CF_BOOL_DECL],
 571 [
 572 AC_MSG_CHECKING(if we should include stdbool.h)
 573
 574 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 575         AC_TRY_COMPILE([],[bool foo = false],
 576                 [cf_cv_header_stdbool_h=0],
 577                 [AC_TRY_COMPILE([
 578 #ifndef __BEOS__
 579 #include <stdbool.h>
 580 #endif
 581 ],[bool foo = false],
 582                         [cf_cv_header_stdbool_h=1],
 583                         [cf_cv_header_stdbool_h=0])])])
 584
 585 if test "$cf_cv_header_stdbool_h" = 1
 586 then    AC_MSG_RESULT(yes)
 587 else    AC_MSG_RESULT(no)
 588 fi
 589
 590 AC_MSG_CHECKING([for builtin bool type])
 591
 592 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 593         AC_TRY_COMPILE([
 594 #include <stdio.h>
 595 #include <sys/types.h>
 596 ],[bool x = false],
 597                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 598                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 599         ])
 600
 601 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 602 then    AC_MSG_RESULT(yes)
 603 else    AC_MSG_RESULT(no)
 604 fi
 605 ])dnl
 606 dnl ---------------------------------------------------------------------------
 607 dnl CF_BOOL_SIZE version: 17 updated: 2020/10/24 19:48:55
 608 dnl ------------
 609 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 610 dnl Don't bother looking for bool.h, since it's been deprecated.
 611 dnl
 612 dnl If the current compiler is C rather than C++, we get the bool definition
 613 dnl from <stdbool.h>.
 614 AC_DEFUN([CF_BOOL_SIZE],
 615 [
 616 AC_CHECK_SIZEOF(bool,,[
 617 #include <stdlib.h>
 618 #include <stdio.h>
 619
 620 #if defined(__cplusplus)
 621
 622 #ifdef HAVE_GXX_BUILTIN_H
 623 #include <g++/builtin.h>
 624 #elif HAVE_GPP_BUILTIN_H
 625 #include <gpp/builtin.h>
 626 #elif HAVE_BUILTIN_H
 627 #include <builtin.h>
 628 #endif
 629
 630 #else
 631
 632 #if $cf_cv_header_stdbool_h
 633 #include <stdbool.h>
 634 #endif
 635
 636 #endif
 637 ])
 638
 639 AC_CACHE_CHECK(for type of bool, cf_cv_type_of_bool,[
 640         rm -f cf_test.out
 641         AC_TRY_RUN([
 642 #include <stdlib.h>
 643 #include <stdio.h>
 644
 645 #if defined(__cplusplus)
 646
 647 #ifdef HAVE_GXX_BUILTIN_H
 648 #include <g++/builtin.h>
 649 #elif HAVE_GPP_BUILTIN_H
 650 #include <gpp/builtin.h>
 651 #elif HAVE_BUILTIN_H
 652 #include <builtin.h>
 653 #endif
 654
 655 #else
 656
 657 #if $cf_cv_header_stdbool_h
 658 #include <stdbool.h>
 659 #endif
 660
 661 #endif
 662
 663 int main(void)
 664 {
 665         FILE *fp = fopen("cf_test.out", "w");
 666         if (fp != 0) {
 667                 bool x = true;
 668                 if ((bool)(-x) >= 0)
 669                         fputs("unsigned ", fp);
 670                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 671                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 672                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 673                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 674                 fclose(fp);
 675         }
 676         ${cf_cv_main_return:-return}(0);
 677 }
 678                 ],
 679                 [cf_cv_type_of_bool=`cat cf_test.out`
 680                  if test -z "$cf_cv_type_of_bool"; then
 681                    cf_cv_type_of_bool=unknown
 682                  fi],
 683                 [cf_cv_type_of_bool=unknown],
 684                 [
 685                 case x$ac_cv_sizeof_bool in
 686                 (x1) cf_cv_type_of_bool="unsigned char";;
 687                 (x2) cf_cv_type_of_bool="unsigned short";;
 688                 (x4) cf_cv_type_of_bool="unsigned int";;
 689                 (x8) cf_cv_type_of_bool="unsigned long";;
 690                 (*)  cf_cv_type_of_bool=unknown;;
 691                 esac
 692                 ])
 693         rm -f cf_test.out
 694 ])
 695
 696 if test "$cf_cv_type_of_bool" = unknown ; then
 697         case .$NCURSES_BOOL in
 698         (.auto|.) NCURSES_BOOL=unsigned;;
 699         esac
 700         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 701         cf_cv_type_of_bool=$NCURSES_BOOL
 702 fi
 703 ])dnl
 704 dnl ---------------------------------------------------------------------------
 705 dnl CF_BUILD_CC version: 8 updated: 2018/01/04 20:31:04
 706 dnl -----------
 707 dnl If we're cross-compiling, allow the user to override the tools and their
 708 dnl options.  The configure script is oriented toward identifying the host
 709 dnl compiler, etc., but we need a build compiler to generate parts of the
 710 dnl source.
 711 dnl
 712 dnl $1 = default for $CPPFLAGS
 713 dnl $2 = default for $LIBS
 714 AC_DEFUN([CF_BUILD_CC],[
 715 CF_ACVERSION_CHECK(2.52,,
 716         [AC_REQUIRE([CF_PROG_EXT])])
 717 if test "$cross_compiling" = yes ; then
 718
 719         # defaults that we might want to override
 720         : ${BUILD_CFLAGS:=''}
 721         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 722         : ${BUILD_LDFLAGS:=''}
 723         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 724         : ${BUILD_EXEEXT:='$x'}
 725         : ${BUILD_OBJEXT:='o'}
 726
 727         AC_ARG_WITH(build-cc,
 728                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 729                 [BUILD_CC="$withval"],
 730                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 731         AC_MSG_CHECKING(for native build C compiler)
 732         AC_MSG_RESULT($BUILD_CC)
 733
 734         AC_MSG_CHECKING(for native build C preprocessor)
 735         AC_ARG_WITH(build-cpp,
 736                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 737                 [BUILD_CPP="$withval"],
 738                 [BUILD_CPP='${BUILD_CC} -E'])
 739         AC_MSG_RESULT($BUILD_CPP)
 740
 741         AC_MSG_CHECKING(for native build C flags)
 742         AC_ARG_WITH(build-cflags,
 743                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 744                 [BUILD_CFLAGS="$withval"])
 745         AC_MSG_RESULT($BUILD_CFLAGS)
 746
 747         AC_MSG_CHECKING(for native build C preprocessor-flags)
 748         AC_ARG_WITH(build-cppflags,
 749                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 750                 [BUILD_CPPFLAGS="$withval"])
 751         AC_MSG_RESULT($BUILD_CPPFLAGS)
 752
 753         AC_MSG_CHECKING(for native build linker-flags)
 754         AC_ARG_WITH(build-ldflags,
 755                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 756                 [BUILD_LDFLAGS="$withval"])
 757         AC_MSG_RESULT($BUILD_LDFLAGS)
 758
 759         AC_MSG_CHECKING(for native build linker-libraries)
 760         AC_ARG_WITH(build-libs,
 761                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 762                 [BUILD_LIBS="$withval"])
 763         AC_MSG_RESULT($BUILD_LIBS)
 764
 765         # this assumes we're on Unix.
 766         BUILD_EXEEXT=
 767         BUILD_OBJEXT=o
 768
 769         : ${BUILD_CC:='${CC}'}
 770
 771         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 772                 AC_MSG_ERROR([Cross-build requires two compilers.
 773 Use --with-build-cc to specify the native compiler.])
 774         fi
 775
 776 else
 777         : ${BUILD_CC:='${CC}'}
 778         : ${BUILD_CPP:='${CPP}'}
 779         : ${BUILD_CFLAGS:='${CFLAGS}'}
 780         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 781         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 782         : ${BUILD_LIBS:='${LIBS}'}
 783         : ${BUILD_EXEEXT:='$x'}
 784         : ${BUILD_OBJEXT:='o'}
 785 fi
 786
 787 AC_SUBST(BUILD_CC)
 788 AC_SUBST(BUILD_CPP)
 789 AC_SUBST(BUILD_CFLAGS)
 790 AC_SUBST(BUILD_CPPFLAGS)
 791 AC_SUBST(BUILD_LDFLAGS)
 792 AC_SUBST(BUILD_LIBS)
 793 AC_SUBST(BUILD_EXEEXT)
 794 AC_SUBST(BUILD_OBJEXT)
 795 ])dnl
 796 dnl ---------------------------------------------------------------------------
 797 dnl CF_CC_ENV_FLAGS version: 9 updated: 2018/07/29 18:03:26
 798 dnl ---------------
 799 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 800 dnl into CC.  This will not help with broken scripts that wrap the compiler
 801 dnl with options, but eliminates a more common category of user confusion.
 802 dnl
 803 dnl In particular, it addresses the problem of being able to run the C
 804 dnl preprocessor in a consistent manner.
 805 dnl
 806 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 807 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 808 dnl outweighs that limitation.
 809 AC_DEFUN([CF_CC_ENV_FLAGS],
 810 [
 811 # This should have been defined by AC_PROG_CC
 812 : ${CC:=cc}
 813
 814 AC_MSG_CHECKING(\$CFLAGS variable)
 815 case "x$CFLAGS" in
 816 (*-[[IUD]]*)
 817         AC_MSG_RESULT(broken)
 818         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 819         cf_flags="$CFLAGS"
 820         CFLAGS=
 821         for cf_arg in $cf_flags
 822         do
 823                 CF_ADD_CFLAGS($cf_arg)
 824         done
 825         ;;
 826 (*)
 827         AC_MSG_RESULT(ok)
 828         ;;
 829 esac
 830
 831 AC_MSG_CHECKING(\$CC variable)
 832 case "$CC" in
 833 (*[[\ \ ]]-*)
 834         AC_MSG_RESULT(broken)
 835         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 836         # humor him...
 837         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 838         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 839         CC="$cf_prog"
 840         for cf_arg in $cf_flags
 841         do
 842                 case "x$cf_arg" in
 843                 (x-[[IUDfgOW]]*)
 844                         CF_ADD_CFLAGS($cf_arg)
 845                         ;;
 846                 (*)
 847                         CC="$CC $cf_arg"
 848                         ;;
 849                 esac
 850         done
 851         CF_VERBOSE(resulting CC: '$CC')
 852         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 853         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 854         ;;
 855 (*)
 856         AC_MSG_RESULT(ok)
 857         ;;
 858 esac
 859 ])dnl
 860 dnl ---------------------------------------------------------------------------
 861 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 862 dnl ---------------
 863 dnl Determine the default configuration into which we'll install ncurses.  This
 864 dnl can be overridden by the user's command-line options.  There's two items to
 865 dnl look for:
 866 dnl     1. the prefix (e.g., /usr)
 867 dnl     2. the header files (e.g., /usr/include/ncurses)
 868 dnl We'll look for a previous installation of ncurses and use the same defaults.
 869 dnl
 870 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 871 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 872 dnl programs from a vendor's.
 873 AC_DEFUN([CF_CFG_DEFAULTS],
 874 [
 875 AC_MSG_CHECKING(for prefix)
 876 if test "x$prefix" = "xNONE" ; then
 877         case "$cf_cv_system_name" in
 878                 # non-vendor systems don't have a conflict
 879         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 880                 prefix=/usr
 881                 ;;
 882         (*)     prefix=$ac_default_prefix
 883                 ;;
 884         esac
 885 fi
 886 AC_MSG_RESULT($prefix)
 887
 888 if test "x$prefix" = "xNONE" ; then
 889 AC_MSG_CHECKING(for default include-directory)
 890 test -n "$verbose" && echo 1>&AC_FD_MSG
 891 for cf_symbol in \
 892         $includedir \
 893         $includedir/ncurses \
 894         $prefix/include \
 895         $prefix/include/ncurses \
 896         /usr/local/include \
 897         /usr/local/include/ncurses \
 898         /usr/include \
 899         /usr/include/ncurses
 900 do
 901         cf_dir=`eval echo $cf_symbol`
 902         if test -f $cf_dir/curses.h ; then
 903         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 904                 includedir="$cf_symbol"
 905                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 906                 break
 907         fi
 908         fi
 909         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 910 done
 911 AC_MSG_RESULT($includedir)
 912 fi
 913 ])dnl
 914 dnl ---------------------------------------------------------------------------
 915 dnl CF_CGETENT version: 6 updated: 2017/01/21 11:06:25
 916 dnl ----------
 917 dnl Check if the terminal-capability database functions are available.  If not,
 918 dnl ncurses has a much-reduced version.
 919 AC_DEFUN([CF_CGETENT],[
 920 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 921 AC_TRY_LINK([
 922 #include <stdlib.h>],[
 923         char temp[128];
 924         char *buf = temp;
 925         char *db_array = temp;
 926         cgetent(&buf, &db_array, "vt100");
 927         cgetcap(buf, "tc", '=');
 928         cgetmatch(buf, "tc");
 929         ],
 930         [cf_cv_cgetent=yes],
 931         [cf_cv_cgetent=no])
 932 ])
 933
 934 if test "$cf_cv_cgetent" = yes
 935 then
 936         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 937 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 938 AC_TRY_LINK([
 939 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
 940 #include <stdlib.h>],[
 941         char temp[128];
 942         char *buf = temp;
 943 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 944         const char *db_array = temp;
 945         cgetent(&buf, &db_array, "vt100");
 946 #endif
 947         cgetcap(buf, "tc", '=');
 948         cgetmatch(buf, "tc");
 949         ],
 950         [cf_cv_cgetent_const=yes],
 951         [cf_cv_cgetent_const=no])
 952 ])
 953         if test "$cf_cv_cgetent_const" = yes
 954         then
 955                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 956         fi
 957 fi
 958 ])dnl
 959 dnl ---------------------------------------------------------------------------
 960 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 961 dnl --------------
 962 dnl Check if we're accidentally using a cache from a different machine.
 963 dnl Derive the system name, as a check for reusing the autoconf cache.
 964 dnl
 965 dnl If we've packaged config.guess and config.sub, run that (since it does a
 966 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 967 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 968 dnl which is useful in cross-compiles.
 969 dnl
 970 dnl Note: we would use $ac_config_sub, but that is one of the places where
 971 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 972 AC_DEFUN([CF_CHECK_CACHE],
 973 [
 974 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 975         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 976         system_name="$host_os"
 977 else
 978         system_name="`(uname -s -r) 2>/dev/null`"
 979         if test -z "$system_name" ; then
 980                 system_name="`(hostname) 2>/dev/null`"
 981         fi
 982 fi
 983 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 984 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 985
 986 test -z "$system_name" && system_name="$cf_cv_system_name"
 987 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 988
 989 if test ".$system_name" != ".$cf_cv_system_name" ; then
 990         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 991         AC_MSG_ERROR("Please remove config.cache and try again.")
 992 fi
 993 ])dnl
 994 dnl ---------------------------------------------------------------------------
 995 dnl CF_CHECK_ENVIRON version: 3 updated: 2010/05/26 16:44:57
 996 dnl ----------------
 997 dnl Check for data that is usually declared in <unistd.h>, e.g., the 'environ'
 998 dnl variable.  Define a DECL_xxx symbol if we must declare it ourselves.
 999 dnl
1000 dnl $1 = the name to check
1001 dnl $2 = the assumed type
1002 AC_DEFUN([CF_CHECK_ENVIRON],
1003 [
1004 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1005     AC_TRY_COMPILE([
1006 #ifdef HAVE_STDLIB_H
1007 #include <stdlib.h>
1008 #endif
1009 #include <unistd.h> ],
1010     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
1011     [cf_cv_dcl_$1=yes],
1012     [cf_cv_dcl_$1=no])
1013 ])
1014
1015 if test "$cf_cv_dcl_$1" = no ; then
1016     CF_UPPER(cf_result,decl_$1)
1017     AC_DEFINE_UNQUOTED($cf_result)
1018 fi
1019
1020 # It's possible (for near-UNIX clones) that the data doesn't exist
1021 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1022 ])dnl
1023 dnl ---------------------------------------------------------------------------
1024 dnl CF_CHECK_ERRNO version: 13 updated: 2020/03/10 18:53:47
1025 dnl --------------
1026 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
1027 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
1028 dnl ourselves.
1029 dnl
1030 dnl $1 = the name to check
1031 dnl $2 = the assumed type
1032 AC_DEFUN([CF_CHECK_ERRNO],
1033 [
1034 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1035         AC_TRY_COMPILE([
1036 #ifdef HAVE_STDLIB_H
1037 #include <stdlib.h>
1038 #endif
1039 #include <stdio.h>
1040 #include <sys/types.h>
1041 #include <errno.h> ],
1042         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1; (void)x,
1043         [cf_cv_dcl_$1=yes],
1044         [cf_cv_dcl_$1=no])
1045 ])
1046
1047 if test "$cf_cv_dcl_$1" = no ; then
1048         CF_UPPER(cf_result,decl_$1)
1049         AC_DEFINE_UNQUOTED($cf_result)
1050 fi
1051
1052 # It's possible (for near-UNIX clones) that the data doesn't exist
1053 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1054 ])dnl
1055 dnl ---------------------------------------------------------------------------
1056 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
1057 dnl --------------------
1058 dnl Check for existence of external data in the current set of libraries.  If
1059 dnl we can modify it, it's real enough.
1060 dnl $1 = the name to check
1061 dnl $2 = its type
1062 AC_DEFUN([CF_CHECK_EXTERN_DATA],
1063 [
1064 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
1065         AC_TRY_LINK([
1066 #undef $1
1067 extern $2 $1;
1068 ],
1069         [$1 = 2],
1070         [cf_cv_have_$1=yes],
1071         [cf_cv_have_$1=no])
1072 ])
1073
1074 if test "$cf_cv_have_$1" = yes ; then
1075         CF_UPPER(cf_result,have_$1)
1076         AC_DEFINE_UNQUOTED($cf_result)
1077 fi
1078
1079 ])dnl
1080 dnl ---------------------------------------------------------------------------
1081 dnl CF_CHECK_FVISIBILITY version: 2 updated: 2020/04/04 16:16:13
1082 dnl --------------------
1083 dnl Check whether the compiler understands -fvisibility=hidden
1084 dnl
1085 dnl $1 = compiler
1086 dnl $2 = compiler-flags variable name
1087 dnl $3 = cache variable to set
1088 AC_DEFUN([CF_CHECK_FVISIBILITY],[
1089 AC_CACHE_CHECK(if $1 -fvisibility=hidden option works,$3,[
1090     cf_save_cflags="[$]$2"
1091     $2="[$]$2 -fvisibility=hidden"
1092     AC_TRY_LINK([
1093 __attribute__ ((visibility("default"))) int somefunc() {return 42;}
1094         ],[
1095         if (somefunc()) return 1;
1096 ],
1097     [$3=yes],
1098     [$3=no])
1099     $2=$cf_save_cflags
1100 ])
1101 ])dnl
1102 dnl ---------------------------------------------------------------------------
1103 dnl CF_CHECK_GETENV version: 1 updated: 2019/06/23 15:28:15
1104 dnl ---------------
1105 dnl Check if repeated getenv calls return the same pointer, e.g., it does not
1106 dnl discard the previous pointer when returning a new one.
1107 AC_DEFUN([CF_CHECK_GETENV],
1108 [
1109 AC_REQUIRE([CF_CHECK_ENVIRON])
1110 AC_CHECK_FUNC( getenv, ,, AC_MSG_ERROR(getenv not found) )
1111 AC_CHECK_FUNCS( putenv setenv strdup )
1112 AC_CACHE_CHECK(if getenv returns consistent values,cf_cv_consistent_getenv,[
1113 AC_TRY_RUN([
1114 #include <stdlib.h>
1115 #include <unistd.h>
1116 #include <stdio.h>
1117 #include <string.h>
1118 #include <sys/types.h>
1119
1120 #if defined(HAVE_ENVIRON) && defined(DECL_ENVIRON) && !defined(environ)
1121 extern char **environ;  /* POSIX, but some systems are not... */
1122 #endif
1123
1124 #if defined(HAVE_STRDUP)
1125 #define str_alloc(s) strdup(s)
1126 #else
1127 #define str_alloc(s) strcpy(malloc(strlen(s) + 1, s))
1128 #endif
1129
1130 static void set_value(const char *name, const char *value)
1131 {
1132 #if defined(HAVE_SETENV)
1133         setenv(name, value, 1);
1134 #elif defined(HAVE_PUTENV)
1135         char buffer[1024];
1136         sprintf(buffer, "%s=%s", name, value);
1137         putenv(str_alloc(buffer));
1138 #else
1139 #error neither putenv/setenv found
1140 #endif
1141 }
1142 int main(void)
1143 {
1144         int pass;
1145         size_t numenv, limit, j;
1146         char **mynames;
1147         char **myvalues;
1148         char **mypointer;
1149         char *equals;
1150         for (numenv = 0; environ[numenv]; ++numenv) ;
1151         limit = numenv + 10;
1152         mynames = (char **) calloc(limit + 1, sizeof(char *));
1153         myvalues = (char **) calloc(limit + 1, sizeof(char *));
1154         mypointer = (char **) calloc(limit + 1, sizeof(char *));
1155 #if defined(HAVE_ENVIRON)
1156         for (j = 0; environ[j]; ++j) {
1157                 mynames[j] = str_alloc(environ[j]);
1158                 equals = strchr(mynames[j], '=');
1159                 if (equals != 0) {
1160                         *equals++ = '\0';
1161                         myvalues[j] = str_alloc(equals);
1162                 } else {
1163                         myvalues[j] = str_alloc("");
1164                 }
1165         }
1166 #endif
1167         for (j = numenv; j < limit; ++j) {
1168                 char name[80];
1169                 char value[80];
1170                 size_t found;
1171                 size_t k = 0;
1172                 do {
1173                         size_t jk;
1174                         found = 0;
1175                         sprintf(name, "TERM%lu", (unsigned long) k);
1176                         for (jk = 0; jk < j; ++jk) {
1177                                 if (!strcmp(name, mynames[jk])) {
1178                                         found = 1;
1179                                         ++k;
1180                                         break;
1181                                 }
1182                         }
1183                 } while (found);
1184                 sprintf(value, "%lu:%p", (unsigned long) k, &mynames[j]);
1185                 set_value(name, value);
1186                 mynames[j] = str_alloc(name);
1187                 myvalues[j] = str_alloc(value);
1188         }
1189         for (pass = 0; pass < 3; ++pass) {
1190                 for (j = 0; j < limit; ++j) {
1191                         char *value = getenv(mynames[j]);
1192                         if (pass) {
1193                                 if (value == 0) {
1194                                         fprintf(stderr, "getenv returned null for %s\n", mynames[j]);
1195                                         ${cf_cv_main_return:-return}(1);
1196                                 } else if (value != mypointer[j]) {
1197                                         fprintf(stderr, "getenv returned different pointer for %s\n", mynames[j]);
1198                                         ${cf_cv_main_return:-return}(1);
1199                                 } else if (strcmp(value, myvalues[j])) {
1200                                         fprintf(stderr, "getenv returned different value for %s\n", mynames[j]);
1201                                         ${cf_cv_main_return:-return}(1);
1202                                 }
1203                         } else {
1204                                 size_t k;
1205                                 mypointer[j] = value;
1206                                 for (k = 0; k < j; ++k) {
1207                                         if (mypointer[j] == mypointer[k]) {
1208                                                 fprintf(stderr, "getenv returned same pointer for %s and %s\n", mynames[j], mynames[k]);
1209                                                 ${cf_cv_main_return:-return}(1);
1210                                         }
1211                                 }
1212                         }
1213                 }
1214         }
1215         ${cf_cv_main_return:-return}(0);
1216 }
1217 ],
1218 [cf_cv_consistent_getenv=yes],
1219 [cf_cv_consistent_getenv=no],
1220 [cf_cv_consistent_getenv=unknown])
1221 ])
1222
1223 if test "x$cf_cv_consistent_getenv" = xno
1224 then
1225         AC_DEFINE(HAVE_CONSISTENT_GETENV,1,[Define to 1 if getenv repeatably returns the same value for a given name])
1226 fi
1227 ])dnl
1228 dnl ---------------------------------------------------------------------------
1229 dnl CF_CHECK_GNAT_VERSION version: 3 updated: 2020/05/23 19:39:36
1230 dnl ---------------------
1231 AC_DEFUN([CF_CHECK_GNAT_VERSION],
1232 [
1233 AC_REQUIRE([CF_GNAT_VERSION])
1234 case $cf_cv_gnat_version in
1235 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
1236         cf_cv_prog_gnat_correct=yes
1237         ;;
1238 (*)
1239         AC_MSG_WARN(Unsupported GNAT version $cf_cv_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1240         cf_cv_prog_gnat_correct=no
1241         ;;
1242 esac
1243 ])
1244 dnl ---------------------------------------------------------------------------
1245 dnl CF_CHECK_GPM_WGETCH version: 3 updated: 2017/01/21 11:06:25
1246 dnl -------------------
1247 dnl Check if GPM is already linked with curses.  If so - and if the linkage
1248 dnl is not "weak" - warn about this because it can create problems linking
1249 dnl applications with ncurses.
1250 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
1251 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
1252
1253 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
1254 cf_cv_check_gpm_wgetch=unknown
1255 if test "$cross_compiling" != yes ; then
1256
1257 cat >conftest.$ac_ext <<CF_EOF
1258 #include <gpm.h>
1259 int main(void)
1260 {
1261         Gpm_Wgetch();
1262         ${cf_cv_main_return:-return}(0);
1263 }
1264 CF_EOF
1265
1266         cf_save_LIBS="$LIBS"
1267         # This only works if we can look at the symbol table.  If a shared
1268         # library is stripped for install, we cannot use that.  So we're forced
1269         # to rely on the static library, noting that some packagers may not
1270         # include it.
1271         LIBS="-static -lgpm -dynamic $LIBS"
1272         if AC_TRY_EVAL(ac_compile) ; then
1273                 if AC_TRY_EVAL(ac_link) ; then
1274                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
1275                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
1276                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
1277                 fi
1278         fi
1279         rm -rf conftest*
1280         LIBS="$cf_save_LIBS"
1281 fi
1282 ])
1283
1284 if test "$cf_cv_check_gpm_wgetch" != yes ; then
1285         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
1286 fi
1287 ])])dnl
1288 dnl ---------------------------------------------------------------------------
1289 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
1290 dnl ------------------------
1291 dnl Show the version of libtool
1292 dnl
1293 dnl Save the version in a cache variable - this is not entirely a good thing,
1294 dnl but the version string from libtool is very ugly, and for bug reports it
1295 dnl might be useful to have the original string.
1296 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1297 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1298 then
1299         AC_MSG_CHECKING(version of $LIBTOOL)
1300         CF_LIBTOOL_VERSION
1301         AC_MSG_RESULT($cf_cv_libtool_version)
1302         if test -z "$cf_cv_libtool_version" ; then
1303                 AC_MSG_ERROR(This is not GNU libtool)
1304         fi
1305 else
1306         AC_MSG_ERROR(GNU libtool has not been found)
1307 fi
1308 ])dnl
1309 dnl ---------------------------------------------------------------------------
1310 dnl CF_CHECK_WCHAR_H version: 2 updated: 2017/01/21 11:06:25
1311 dnl ----------------
1312 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1313 AC_DEFUN([CF_CHECK_WCHAR_H],[
1314 AC_CHECK_HEADERS( \
1315 wchar.h \
1316 wctype.h \
1317 )
1318 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1319 AC_TRY_COMPILE(
1320 [
1321 #include <stdlib.h>
1322 #ifdef HAVE_WCHAR_H
1323 #include <wchar.h>
1324 #endif
1325 #ifdef HAVE_WCTYPE_H
1326 #include <wctype.h>
1327 #endif
1328 ],[
1329         wint_t foo = 0;
1330         int bar = iswpunct(foo)],
1331         [cf_cv_wchar_h_okay=yes],
1332         [cf_cv_wchar_h_okay=no])])
1333
1334 if test $cf_cv_wchar_h_okay = no
1335 then
1336         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1337 fi
1338 ])dnl
1339 dnl ---------------------------------------------------------------------------
1340 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 1 updated: 2015/12/19 17:47:56
1341 dnl -------------------------
1342 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1343 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1344 dnl
1345 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1346 dnl all of those were combined into a page of useful graphics characters.
1347 dnl
1348 dnl So far, so good.
1349 dnl
1350 dnl However, while they are useful, there are other considerations.  CJK
1351 dnl is (because of poor device resolution) often rendered as double-width
1352 dnl characters.  So... for these generally-useful characters, what should
1353 dnl be the width (to make them consistent with adjacent characters)?
1354 dnl
1355 dnl The obvious choice would have been to make this locale-dependent, and use
1356 dnl wcwidth() to tell applications what the actual width is.  That was too
1357 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1358 dnl See for example
1359 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1360 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1361 dnl
1362 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1363 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1364 dnl instance, it lists half (44/96) of the Latin-1 characters as
1365 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1366 dnl
1367 dnl What this means for the implementor is that on some systems wcwidth() can
1368 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1369 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1370 dnl characters).  These do not necessarily match the behavior of the terminal
1371 dnl emulator.  xterm, for instance, does an optional startup check to find if
1372 dnl this problem (or similar) exists with the system's locale tables, rejecting
1373 dnl them if they are too unreliable.
1374 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1375 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1376 cat >conftest.in <<CF_EOF
1377 -       VT100 symbols
1378 0x250c  upper left corner
1379 0x2514  lower left corner
1380 0x2510  upper right corner
1381 0x2518  lower right corner
1382 0x251c  tee pointing left
1383 0x2524  tee pointing right
1384 0x2534  tee pointing up
1385 0x252c  tee pointing down
1386 0x2500  horizontal line
1387 0x2502  vertical line
1388 0x253c  large plus or crossover
1389 0x23ba  scan line 1
1390 0x23bd  scan line 9
1391 0x25c6  diamond
1392 0x2592  checker board (stipple)
1393 0x00b0  degree symbol
1394 0x00b1  plus/minus
1395 0x00b7  bullet
1396 -       Teletype 5410v1 symbols
1397 0x2190  arrow pointing left
1398 0x2192  arrow pointing right
1399 0x2193  arrow pointing down
1400 0x2191  arrow pointing up
1401 0x2592  board of squares
1402 0x2603  lantern symbol
1403 0x25ae  solid square block
1404 -       these defaults were invented for ncurses
1405 0x23bb  scan line 3
1406 0x23bc  scan line 7
1407 0x2264  less-than-or-equal-to
1408 0x2265  greater-than-or-equal-to
1409 0x03c0  greek pi
1410 0x2260  not-equal
1411 0x00a3  pound-sterling symbol
1412 -       thick-line-drawing
1413 0x250f  upper left corner
1414 0x2517  lower left corner
1415 0x2513  upper right corner
1416 0x251b  lower right corner
1417 0x2523  tee pointing left
1418 0x252b  tee pointing right
1419 0x253b  tee pointing up
1420 0x2533  tee pointing down
1421 0x2501  horizontal line
1422 0x2503  vertical line
1423 0x254b  large plus or crossover
1424 -       double-line-drawing
1425 0x2554  upper left corner
1426 0x255a  lower left corner
1427 0x2557  upper right corner
1428 0x255d  lower right corner
1429 0x2563  tee pointing left
1430 0x2560  tee pointing right
1431 0x2569  tee pointing up
1432 0x2566  tee pointing down
1433 0x2550  horizontal line
1434 0x2551  vertical line
1435 0x256c  large plus or crossover
1436 CF_EOF
1437 AC_TRY_RUN([
1438 #include <locale.h>
1439 #include <stdio.h>
1440 #include <wchar.h>
1441
1442 #define MY_LEN 80
1443
1444 int
1445 main(void)
1446 {
1447         FILE *fp;
1448         int value;
1449         char buffer[MY_LEN + 1];
1450         char notes[MY_LEN + 1];
1451         int totals = 0;
1452         int passed = 0;
1453
1454         if (setlocale(LC_ALL, "en_US.UTF8") ||
1455                 setlocale(LC_ALL, "en_US.UTF-8") ||
1456                 setlocale(LC_ALL, "en_US.utf8") ||
1457                 setlocale(LC_ALL, "en_US.utf-8")) {
1458                 if ((fp = fopen("conftest.in", "r")) != 0) {
1459                         while (fgets(buffer, MY_LEN, fp) != 0) {
1460                                 if (*buffer == '-') {
1461                                         fprintf(stderr, "\t%s", buffer);
1462                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1463                                         ++totals;
1464                                         if (wcwidth(value) == 1)
1465                                                 ++passed;
1466                                         fprintf(stderr, "%d\t%s", wcwidth(value), buffer);
1467                                 } else {
1468                                         fprintf(stderr, "?\t%s", buffer);
1469                                 }
1470                         }
1471                 }
1472         }
1473         fprintf(stderr, "%d/%d passed wcwidth/graphics check\n", passed, totals);
1474         return (totals == passed) ? 0 : 1;
1475 }
1476 ],
1477 [cf_cv_wcwidth_graphics=yes],
1478 [cf_cv_wcwidth_graphics=no],
1479 [cf_cv_wcwidth_graphics=unknown])
1480 ])
1481 ])dnl
1482 dnl ---------------------------------------------------------------------------
1483 dnl CF_CLANG_COMPILER version: 4 updated: 2020/10/31 15:46:50
1484 dnl -----------------
1485 dnl Check if the given compiler is really clang.  clang's C driver defines
1486 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1487 dnl not ignore some gcc options.
1488 dnl
1489 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1490 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1491 dnl the wrappers for gcc and g++ warnings.
1492 dnl
1493 dnl $1 = GCC (default) or GXX
1494 dnl $2 = CLANG_COMPILER (default)
1495 dnl $3 = CFLAGS (default) or CXXFLAGS
1496 AC_DEFUN([CF_CLANG_COMPILER],[
1497 ifelse([$2],,CLANG_COMPILER,[$2])=no
1498
1499 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1500         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1501         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1502         AC_TRY_COMPILE([],[
1503 #ifdef __clang__
1504 #else
1505 make an error
1506 #endif
1507 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1508 ],[])
1509         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1510         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1511 fi
1512
1513 if test "x$ifelse([$2],,CLANG_COMPILER,[$2])" = "xyes" ; then
1514         for cf_clang_opt in \
1515                 -Qunused-arguments \
1516                 -Wno-error=implicit-function-declaration
1517         do
1518                 AC_MSG_CHECKING(if option $cf_clang_opt works)
1519                 AC_TRY_LINK([
1520                         #include <stdio.h>],[
1521                         printf("hello!\n");],[
1522                         cf_clang_optok=yes],[
1523                         cf_clang_optok=no])
1524                 AC_MSG_RESULT($cf_clang_optok)
1525                 if test $cf_clang_optok = yes; then
1526                         CF_VERBOSE(adding option $cf_clang_opt)
1527                         CF_APPEND_TEXT(CFLAGS,$cf_clang_opt)
1528                 fi
1529         done
1530 fi
1531 ])
1532 dnl ---------------------------------------------------------------------------
1533 dnl CF_CONST_X_STRING version: 4 updated: 2020/03/10 18:53:47
1534 dnl -----------------
1535 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
1536 dnl character-strings.
1537 dnl
1538 dnl It is ambiguous because the specification accommodated the pre-ANSI
1539 dnl compilers bundled by more than one vendor in lieu of providing a standard C
1540 dnl compiler other than by costly add-ons.  Because of this, the specification
1541 dnl did not take into account the use of const for telling the compiler that
1542 dnl string literals would be in readonly memory.
1543 dnl
1544 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
1545 dnl let the compiler decide how to represent Xt's strings which were #define'd.
1546 dnl That does not solve the problem of using the block of Xt's strings which
1547 dnl are compiled into the library (and is less efficient than one might want).
1548 dnl
1549 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
1550 dnl when compiling the library and compiling using the library, to tell the
1551 dnl compiler that String is const.
1552 AC_DEFUN([CF_CONST_X_STRING],
1553 [
1554 AC_REQUIRE([AC_PATH_XTRA])
1555
1556 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
1557
1558 AC_TRY_COMPILE(
1559 [
1560 #include <stdlib.h>
1561 #include <X11/Intrinsic.h>
1562 ],
1563 [String foo = malloc(1); (void)foo],[
1564
1565 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
1566         AC_TRY_COMPILE(
1567                 [
1568 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
1569 #undef  XTSTRINGDEFINES /* X11R5 and later */
1570 #include <stdlib.h>
1571 #include <X11/Intrinsic.h>
1572                 ],[String foo = malloc(1); *foo = 0],[
1573                         cf_cv_const_x_string=no
1574                 ],[
1575                         cf_cv_const_x_string=yes
1576                 ])
1577 ])
1578
1579 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
1580
1581 case $cf_cv_const_x_string in
1582 (no)
1583         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
1584         ;;
1585 (*)
1586         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
1587         ;;
1588 esac
1589
1590 ])
1591 ])dnl
1592 dnl ---------------------------------------------------------------------------
1593 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1594 dnl -----------------
1595 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1596 dnl is a late feature for the standard and is not in some recent compilers
1597 dnl (1999/9/11).
1598 AC_DEFUN([CF_CPP_PARAM_INIT],
1599 [
1600 if test -n "$CXX"; then
1601 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1602         AC_LANG_SAVE
1603         AC_LANG_CPLUSPLUS
1604         AC_TRY_RUN([
1605 class TEST {
1606 private:
1607         int value;
1608 public:
1609         TEST(int x = 1);
1610         ~TEST();
1611 };
1612
1613 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1614 {
1615         value = x;
1616 }
1617 int main(void) { }
1618 ],
1619         [cf_cv_cpp_param_init=yes],
1620         [cf_cv_cpp_param_init=no],
1621         [cf_cv_cpp_param_init=unknown])
1622         AC_LANG_RESTORE
1623 ])
1624 fi
1625 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1626 ])dnl
1627 dnl ---------------------------------------------------------------------------
1628 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1629 dnl ------------------
1630 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1631 dnl not be supported in g++ before 3.0
1632 AC_DEFUN([CF_CPP_STATIC_CAST],
1633 [
1634 if test -n "$CXX"; then
1635
1636 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1637         AC_LANG_SAVE
1638         AC_LANG_CPLUSPLUS
1639
1640         AC_TRY_COMPILE([
1641 class NCursesPanel
1642 {
1643 public:
1644   NCursesPanel(int nlines,
1645                int ncols,
1646                int begin_y = 0,
1647                int begin_x = 0)
1648   {
1649   }
1650   NCursesPanel();
1651   ~NCursesPanel();
1652 };
1653
1654 template<class T> class NCursesUserPanel : public NCursesPanel
1655 {
1656 public:
1657   NCursesUserPanel (int nlines,
1658                     int ncols,
1659                     int begin_y = 0,
1660                     int begin_x = 0,
1661                     const T* p_UserData = static_cast<T*>(0))
1662     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1663   {
1664   };
1665   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1666   {
1667   };
1668
1669   virtual ~NCursesUserPanel() {};
1670 };
1671 ],[
1672         const char* p_UserData = static_cast<char*>(0)],
1673         [cf_cv_cpp_static_cast=yes],
1674         [cf_cv_cpp_static_cast=no])
1675
1676         AC_LANG_RESTORE
1677 ])
1678
1679 fi
1680
1681 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1682 ])dnl
1683 dnl ---------------------------------------------------------------------------
1684 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1685 dnl ---------------
1686 dnl Setup special archiver flags for given compilers.
1687 AC_DEFUN([CF_CXX_AR_FLAGS],[
1688         CXX_AR='$(AR)'
1689         CXX_ARFLAGS='$(ARFLAGS)'
1690         case $cf_cv_system_name in
1691         (irix*)
1692             if test "$GXX" != yes ; then
1693                 CXX_AR='$(CXX)'
1694                 CXX_ARFLAGS='-ar -o'
1695             fi
1696             ;;
1697         (sco3.2v5*)
1698             CXXLDFLAGS="-u main"
1699             ;;
1700         (solaris2*)
1701             if test "$GXX" != yes ; then
1702                 CXX_AR='$(CXX)'
1703                 CXX_ARFLAGS='-xar -o'
1704             fi
1705             ;;
1706         esac
1707         AC_SUBST(CXXLDFLAGS)
1708         AC_SUBST(CXX_AR)
1709         AC_SUBST(CXX_ARFLAGS)
1710 ])dnl
1711 dnl ---------------------------------------------------------------------------
1712 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1713 dnl -------------------------
1714 dnl For c++, check if iostream uses "std::" namespace.
1715 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1716 AC_CHECK_HEADERS(iostream)
1717 if test x"$ac_cv_header_iostream" = xyes ; then
1718         AC_MSG_CHECKING(if iostream uses std-namespace)
1719         AC_TRY_COMPILE([
1720 #include <iostream>
1721 using std::endl;
1722 using std::cerr;],[
1723 cerr << "testing" << endl;
1724 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1725         AC_MSG_RESULT($cf_iostream_namespace)
1726         if test "$cf_iostream_namespace" = yes ; then
1727                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1728         fi
1729 fi
1730 ])dnl
1731 dnl ---------------------------------------------------------------------------
1732 dnl CF_C_INLINE version: 6 updated: 2019/09/07 13:38:36
1733 dnl -----------
1734 dnl Check if the C compiler supports "inline".
1735 dnl $1 is the name of a shell variable to set if inline is supported
1736 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1737 AC_DEFUN([CF_C_INLINE],[
1738 AC_REQUIRE([CF_GCC_VERSION])
1739 AC_C_INLINE
1740 $1=
1741 if test "$ac_cv_c_inline" != no ; then
1742         $1=inline
1743         if test "$INTEL_COMPILER" = yes
1744         then
1745                 :
1746         elif test "$CLANG_COMPILER" = yes
1747         then
1748                 :
1749         elif test "$GCC" = yes
1750         then
1751                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1752                 cf_save_CFLAGS=$CFLAGS
1753                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1754                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1755                 [${cf_cv_main_return:-return} foo()],
1756                 [cf_cv_gcc_inline=yes],
1757                 [cf_cv_gcc_inline=no])
1758                 CFLAGS=$cf_save_CFLAGS
1759                 ])
1760                 if test "$cf_cv_gcc_inline" = yes ; then
1761                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1762                 fi
1763         fi
1764 fi
1765 AC_SUBST($1)
1766 ])dnl
1767 dnl ---------------------------------------------------------------------------
1768 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1769 dnl ----------
1770 dnl "dirname" is not portable, so we fake it with a shell script.
1771 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1772 dnl ---------------------------------------------------------------------------
1773 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1774 dnl ---------------
1775 AC_DEFUN([CF_DIRS_TO_MAKE],
1776 [
1777 DIRS_TO_MAKE="lib"
1778 for cf_item in $cf_list_models
1779 do
1780         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1781         for cf_item2 in $DIRS_TO_MAKE
1782         do
1783                 test $cf_item2 = $cf_subdir && break
1784         done
1785         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1786 done
1787 for cf_dir in $DIRS_TO_MAKE
1788 do
1789         test ! -d $cf_dir && mkdir $cf_dir
1790 done
1791 AC_SUBST(DIRS_TO_MAKE)
1792 ])dnl
1793 dnl ---------------------------------------------------------------------------
1794 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1795 dnl ---------------
1796 dnl You can always use "make -n" to see the actual options, but it's hard to
1797 dnl pick out/analyze warning messages when the compile-line is long.
1798 dnl
1799 dnl Sets:
1800 dnl     ECHO_LT - symbol to control if libtool is verbose
1801 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1802 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1803 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1804 dnl     ECHO_CC - symbol to put before any "cc" line
1805 dnl
1806 AC_DEFUN([CF_DISABLE_ECHO],[
1807 AC_MSG_CHECKING(if you want to see long compiling messages)
1808 CF_ARG_DISABLE(echo,
1809         [  --disable-echo          do not display "compiling" commands],
1810         [
1811         ECHO_LT='--silent'
1812         ECHO_LD='@echo linking [$]@;'
1813         RULE_CC='@echo compiling [$]<'
1814         SHOW_CC='@echo compiling [$]@'
1815         ECHO_CC='@'
1816 ],[
1817         ECHO_LT=''
1818         ECHO_LD=''
1819         RULE_CC=''
1820         SHOW_CC=''
1821         ECHO_CC=''
1822 ])
1823 AC_MSG_RESULT($enableval)
1824 AC_SUBST(ECHO_LT)
1825 AC_SUBST(ECHO_LD)
1826 AC_SUBST(RULE_CC)
1827 AC_SUBST(SHOW_CC)
1828 AC_SUBST(ECHO_CC)
1829 ])dnl
1830 dnl ---------------------------------------------------------------------------
1831 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1832 dnl ------------------------
1833 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1834 AC_MSG_CHECKING(if we want to use GNAT projects)
1835 CF_ARG_DISABLE(gnat-projects,
1836         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1837         [enable_gnat_projects=no],
1838         [enable_gnat_projects=yes])
1839 AC_MSG_RESULT($enable_gnat_projects)
1840 ])dnl
1841 dnl ---------------------------------------------------------------------------
1842 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1843 dnl ----------------
1844 dnl Combine no-leak checks with the libraries or tools that are used for the
1845 dnl checks.
1846 AC_DEFUN([CF_DISABLE_LEAKS],[
1847
1848 AC_REQUIRE([CF_WITH_DMALLOC])
1849 AC_REQUIRE([CF_WITH_DBMALLOC])
1850 AC_REQUIRE([CF_WITH_VALGRIND])
1851
1852 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1853 AC_ARG_ENABLE(leaks,
1854         [  --disable-leaks         test: free permanent memory, analyze leaks],
1855         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1856         : ${with_no_leaks:=no})
1857 AC_MSG_RESULT($with_no_leaks)
1858
1859 if test "$with_no_leaks" = yes ; then
1860         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1861         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1862 fi
1863 ])dnl
1864 dnl ---------------------------------------------------------------------------
1865 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1866 dnl --------------------------
1867 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1868 dnl the older "-version-info" feature.  The newer feature allows us to use
1869 dnl version numbering on shared libraries which make them compatible with
1870 dnl various systems.
1871 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1872 [
1873 AC_MSG_CHECKING(if libtool -version-number should be used)
1874 CF_ARG_DISABLE(libtool-version,
1875         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1876         [cf_libtool_version=no],
1877         [cf_libtool_version=yes])
1878 AC_MSG_RESULT($cf_libtool_version)
1879
1880 if test "$cf_libtool_version" = yes ; then
1881         LIBTOOL_VERSION="-version-number"
1882 else
1883         LIBTOOL_VERSION="-version-info"
1884         case "x$VERSION" in
1885         (x)
1886                 AC_MSG_WARN(VERSION was not set)
1887                 ;;
1888         (x*.*.*)
1889                 ABI_VERSION="$VERSION"
1890                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1891                 ;;
1892         (x*:*:*)
1893                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1894                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1895                 ;;
1896         (*)
1897                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1898                 ;;
1899         esac
1900 fi
1901
1902 AC_SUBST(ABI_VERSION)
1903 AC_SUBST(LIBTOOL_VERSION)
1904 ])dnl
1905 dnl ---------------------------------------------------------------------------
1906 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1907 dnl ---------------------
1908 dnl The rpath-hack makes it simpler to build programs, particularly with the
1909 dnl *BSD ports which may have essential libraries in unusual places.  But it
1910 dnl can interfere with building an executable for the base system.  Use this
1911 dnl option in that case.
1912 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1913 [
1914 AC_MSG_CHECKING(if rpath-hack should be disabled)
1915 CF_ARG_DISABLE(rpath-hack,
1916         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1917         [cf_disable_rpath_hack=yes],
1918         [cf_disable_rpath_hack=no])
1919 AC_MSG_RESULT($cf_disable_rpath_hack)
1920 if test "$cf_disable_rpath_hack" = no ; then
1921         CF_RPATH_HACK
1922 fi
1923 ])
1924 dnl ---------------------------------------------------------------------------
1925 dnl CF_ENABLE_BROKEN_LINKER version: 1 updated: 2020/02/08 15:59:30
1926 dnl -----------------------
1927 dnl Some linkers cannot reference a data-only object.  Cygwin used to be one.
1928 dnl This usually follows CF_LINK_DATAONLY, but is not required in case we need
1929 dnl an unconditional feature.
1930 AC_DEFUN([CF_ENABLE_BROKEN_LINKER],[
1931
1932 AC_MSG_CHECKING(if you want broken-linker support code)
1933 AC_ARG_ENABLE(broken_linker,
1934         [  --enable-broken_linker  compile with broken-linker support code],
1935         [with_broken_linker=$enableval],
1936         [with_broken_linker=no])
1937 AC_MSG_RESULT($with_broken_linker)
1938
1939 : ${BROKEN_LINKER:=0}
1940 if test "x$with_broken_linker" = xyes ; then
1941         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
1942         BROKEN_LINKER=1
1943 fi
1944 AC_SUBST(BROKEN_LINKER)
1945 ])dnl
1946 dnl ---------------------------------------------------------------------------
1947 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
1948 dnl ------------------
1949 dnl This is the "--enable-pc-files" option, which is available if there is a
1950 dnl pkg-config configuration on the local machine.
1951 AC_DEFUN([CF_ENABLE_PC_FILES],[
1952 AC_REQUIRE([CF_PKG_CONFIG])
1953 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1954
1955 if test "x$PKG_CONFIG" != xnone
1956 then
1957         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1958 else
1959         AC_MSG_CHECKING(if we should install .pc files)
1960 fi
1961
1962 AC_ARG_ENABLE(pc-files,
1963         [  --enable-pc-files       generate and install .pc files for pkg-config],
1964         [enable_pc_files=$enableval],
1965         [enable_pc_files=no])
1966 AC_MSG_RESULT($enable_pc_files)
1967
1968 if test "x$enable_pc_files" != xno
1969 then
1970         MAKE_PC_FILES=
1971         case "x$PKG_CONFIG_LIBDIR" in
1972         (xno|xyes)
1973                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1974                 ;;
1975         (*)
1976                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1977                 ;;
1978         esac
1979 else
1980         MAKE_PC_FILES="#"
1981 fi
1982 AC_SUBST(MAKE_PC_FILES)
1983 ])dnl
1984 dnl ---------------------------------------------------------------------------
1985 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1986 dnl ---------------
1987 dnl Check if the rpath option should be used, setting cache variable
1988 dnl cf_cv_enable_rpath if so.
1989 AC_DEFUN([CF_ENABLE_RPATH],
1990 [
1991 AC_MSG_CHECKING(if rpath option should be used)
1992 AC_ARG_ENABLE(rpath,
1993 [  --enable-rpath          use rpath option when generating shared libraries],
1994 [cf_cv_enable_rpath=$enableval],
1995 [cf_cv_enable_rpath=no])
1996 AC_MSG_RESULT($cf_cv_enable_rpath)
1997 ])dnl
1998 dnl ---------------------------------------------------------------------------
1999 dnl CF_ENABLE_STRING_HACKS version: 5 updated: 2016/10/08 17:34:11
2000 dnl ----------------------
2001 dnl On a few platforms, the compiler and/or loader nags with untruthful
2002 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
2003 dnl and implying that most uses of the recommended alternatives are correct.
2004 dnl
2005 dnl Factually speaking, no one has actually counted the number of uses of these
2006 dnl functions versus the total of incorrect uses.  Samples of a few thousand
2007 dnl instances are meaningless compared to the hundreds of millions of lines of
2008 dnl existing C code.
2009 dnl
2010 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
2011 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
2012 dnl standard - but evolved through phases, and older implementations are likely
2013 dnl to yield surprising results, as documented in manpages on various systems.
2014 AC_DEFUN([CF_ENABLE_STRING_HACKS],
2015 [
2016 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
2017 AC_ARG_ENABLE(string-hacks,
2018         [  --enable-string-hacks   work around bogus compiler/loader warnings],
2019         [with_string_hacks=$enableval],
2020         [with_string_hacks=no])
2021 AC_MSG_RESULT($with_string_hacks)
2022
2023 if test "x$with_string_hacks" = "xyes"; then
2024         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
2025         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
2026         AC_CHECK_FUNC(strlcat,[
2027                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2028                 ],[
2029                 AC_CHECK_LIB(bsd,strlcat,[
2030                         CF_ADD_LIB(bsd)
2031                         AC_CHECK_HEADERS(bsd/string.h)
2032                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2033                         ])
2034                 ])
2035         AC_CHECK_FUNCS( strlcpy snprintf )
2036 fi
2037 ])dnl
2038 dnl ---------------------------------------------------------------------------
2039 dnl CF_ENABLE_WARNINGS version: 7 updated: 2020/08/29 09:05:21
2040 dnl ------------------
2041 dnl Configure-option to enable gcc warnings
2042 dnl
2043 dnl $1 = extra options to add, if supported
2044 dnl $2 = option for checking attributes.  By default, this is done when
2045 dnl      warnings are enabled.  For other values:
2046 dnl      yes: always do this, e.g., to use in generated library-headers
2047 dnl      no: never do this
2048 AC_DEFUN([CF_ENABLE_WARNINGS],[
2049 if ( test "$GCC" = yes || test "$GXX" = yes )
2050 then
2051 CF_FIX_WARNINGS(CFLAGS)
2052 CF_FIX_WARNINGS(CPPFLAGS)
2053 CF_FIX_WARNINGS(LDFLAGS)
2054 AC_MSG_CHECKING(if you want to turn on gcc warnings)
2055 CF_ARG_ENABLE(warnings,
2056         [  --enable-warnings       test: turn on gcc compiler warnings],
2057         [with_warnings=yes],
2058         [with_warnings=no])
2059 AC_MSG_RESULT($with_warnings)
2060 if test "$with_warnings" = "yes"
2061 then
2062         ifelse($2,,[CF_GCC_ATTRIBUTES])
2063         CF_GCC_WARNINGS($1)
2064 fi
2065 ifelse($2,yes,[CF_GCC_ATTRIBUTES])
2066 fi
2067 ])dnl
2068 dnl ---------------------------------------------------------------------------
2069 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
2070 dnl --------
2071 dnl Check if 'errno' is declared in <errno.h>
2072 AC_DEFUN([CF_ERRNO],
2073 [
2074 CF_CHECK_ERRNO(errno)
2075 ])dnl
2076 dnl ---------------------------------------------------------------------------
2077 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
2078 dnl ---------------
2079 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
2080 dnl math.h and builtin.h, only for ncurses
2081 AC_DEFUN([CF_ETIP_DEFINES],
2082 [
2083 AC_MSG_CHECKING(for special defines needed for etip.h)
2084 cf_save_CXXFLAGS="$CXXFLAGS"
2085 cf_result="none"
2086
2087 # etip.h includes ncurses.h which includes ncurses_dll.h
2088 # But ncurses_dll.h is generated - fix here.
2089 test -d include || mkdir include
2090 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
2091
2092 for cf_math in "" MATH_H
2093 do
2094 for cf_excp in "" MATH_EXCEPTION
2095 do
2096         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
2097         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
2098         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
2099 AC_TRY_COMPILE([
2100 #include <etip.h.in>
2101 ],[],[
2102         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
2103         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
2104         cf_result="$cf_math $cf_excp"
2105         break 2
2106 ],[])
2107 done
2108 done
2109 AC_MSG_RESULT($cf_result)
2110 CXXFLAGS="$cf_save_CXXFLAGS"
2111 ])
2112 dnl ---------------------------------------------------------------------------
2113 dnl CF_FIND_LINKAGE version: 21 updated: 2018/06/20 20:23:13
2114 dnl ---------------
2115 dnl Find a library (specifically the linkage used in the code fragment),
2116 dnl searching for it if it is not already in the library path.
2117 dnl See also CF_ADD_SEARCHPATH.
2118 dnl
2119 dnl Parameters (4-on are optional):
2120 dnl     $1 = headers for library entrypoint
2121 dnl     $2 = code fragment for library entrypoint
2122 dnl     $3 = the library name without the "-l" option or ".so" suffix.
2123 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
2124 dnl     $5 = action to perform if not successful
2125 dnl     $6 = module name, if not the same as the library name
2126 dnl     $7 = extra libraries
2127 dnl
2128 dnl Sets these variables:
2129 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
2130 dnl     $cf_cv_header_path_$3 - include-directory if needed
2131 dnl     $cf_cv_library_path_$3 - library-directory if needed
2132 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
2133 AC_DEFUN([CF_FIND_LINKAGE],[
2134
2135 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
2136 # will be set on completion of the AC_TRY_LINK below.
2137 cf_cv_header_path_$3=
2138 cf_cv_library_path_$3=
2139
2140 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
2141
2142 cf_save_LIBS="$LIBS"
2143
2144 AC_TRY_LINK([$1],[$2],[
2145         cf_cv_find_linkage_$3=yes
2146         cf_cv_header_path_$3=/usr/include
2147         cf_cv_library_path_$3=/usr/lib
2148 ],[
2149
2150 LIBS="-l$3 $7 $cf_save_LIBS"
2151
2152 AC_TRY_LINK([$1],[$2],[
2153         cf_cv_find_linkage_$3=yes
2154         cf_cv_header_path_$3=/usr/include
2155         cf_cv_library_path_$3=/usr/lib
2156         cf_cv_library_file_$3="-l$3"
2157 ],[
2158         cf_cv_find_linkage_$3=no
2159         LIBS="$cf_save_LIBS"
2160
2161         CF_VERBOSE(find linkage for $3 library)
2162         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
2163
2164         cf_save_CPPFLAGS="$CPPFLAGS"
2165         cf_test_CPPFLAGS="$CPPFLAGS"
2166
2167         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
2168         for cf_cv_header_path_$3 in $cf_search
2169         do
2170                 if test -d $cf_cv_header_path_$3 ; then
2171                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
2172                         CPPFLAGS="$cf_save_CPPFLAGS"
2173                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
2174                         AC_TRY_COMPILE([$1],[$2],[
2175                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
2176                                 cf_cv_find_linkage_$3=maybe
2177                                 cf_test_CPPFLAGS="$CPPFLAGS"
2178                                 break],[
2179                                 CPPFLAGS="$cf_save_CPPFLAGS"
2180                                 ])
2181                 fi
2182         done
2183
2184         if test "$cf_cv_find_linkage_$3" = maybe ; then
2185
2186                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
2187
2188                 cf_save_LIBS="$LIBS"
2189                 cf_save_LDFLAGS="$LDFLAGS"
2190
2191                 ifelse([$6],,,[
2192                 CPPFLAGS="$cf_test_CPPFLAGS"
2193                 LIBS="-l$3 $7 $cf_save_LIBS"
2194                 AC_TRY_LINK([$1],[$2],[
2195                         CF_VERBOSE(... found $3 library in system)
2196                         cf_cv_find_linkage_$3=yes])
2197                         CPPFLAGS="$cf_save_CPPFLAGS"
2198                         LIBS="$cf_save_LIBS"
2199                         ])
2200
2201                 if test "$cf_cv_find_linkage_$3" != yes ; then
2202                         CF_LIBRARY_PATH(cf_search,$3)
2203                         for cf_cv_library_path_$3 in $cf_search
2204                         do
2205                                 if test -d $cf_cv_library_path_$3 ; then
2206                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
2207                                         CPPFLAGS="$cf_test_CPPFLAGS"
2208                                         LIBS="-l$3 $7 $cf_save_LIBS"
2209                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
2210                                         AC_TRY_LINK([$1],[$2],[
2211                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
2212                                         cf_cv_find_linkage_$3=yes
2213                                         cf_cv_library_file_$3="-l$3"
2214                                         break],[
2215                                         CPPFLAGS="$cf_save_CPPFLAGS"
2216                                         LIBS="$cf_save_LIBS"
2217                                         LDFLAGS="$cf_save_LDFLAGS"
2218                                         ])
2219                                 fi
2220                         done
2221                         CPPFLAGS="$cf_save_CPPFLAGS"
2222                         LDFLAGS="$cf_save_LDFLAGS"
2223                 fi
2224
2225         else
2226                 cf_cv_find_linkage_$3=no
2227         fi
2228         ],$7)
2229 ])
2230
2231 LIBS="$cf_save_LIBS"
2232
2233 if test "$cf_cv_find_linkage_$3" = yes ; then
2234 ifelse([$4],,[
2235         CF_ADD_INCDIR($cf_cv_header_path_$3)
2236         CF_ADD_LIBDIR($cf_cv_library_path_$3)
2237         CF_ADD_LIB($3)
2238 ],[$4])
2239 else
2240 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
2241 fi
2242 ])dnl
2243 dnl ---------------------------------------------------------------------------
2244 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
2245 dnl ------------------
2246 dnl Find an include-directory with the given leaf-name.  This is useful for
2247 dnl example with FreeBSD ports, which use this convention to distinguish
2248 dnl different versions of the same port.
2249 AC_DEFUN([CF_FIND_SUB_INCDIR],[
2250         CF_SUBDIR_PATH(cf_search,$1,include)
2251         for cf_item in $cf_search
2252         do
2253                 case $cf_item in
2254                 (*/$1)
2255                         CF_ADD_INCDIR($cf_item)
2256                         ;;
2257                 esac
2258         done
2259 ])dnl
2260 dnl ---------------------------------------------------------------------------
2261 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
2262 dnl ------------------
2263 dnl Find a library-directory with the given leaf-name.  This is useful for
2264 dnl example with FreeBSD ports, which use this convention to distinguish
2265 dnl different versions of the same port.
2266 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
2267         CF_SUBDIR_PATH(cf_search,$1,lib)
2268         for cf_item in $cf_search
2269         do
2270                 case $cf_item in
2271                 (*/$1)
2272                         CF_ADD_LIBDIR($cf_item)
2273                         ;;
2274                 esac
2275         done
2276 ])dnl
2277 dnl ---------------------------------------------------------------------------
2278 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
2279 dnl -----------------
2280 dnl make ADAFLAGS consistent with CFLAGS
2281 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
2282         AC_MSG_CHECKING(optimization options for ADAFLAGS)
2283         case "$CFLAGS" in
2284         (*-g*)
2285                 CF_ADD_ADAFLAGS(-g)
2286                 ;;
2287         esac
2288         case "$CFLAGS" in
2289         (*-O*)
2290                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
2291                 CF_ADD_ADAFLAGS($cf_O_flag)
2292                 ;;
2293         esac
2294         AC_MSG_RESULT($ADAFLAGS)
2295 ])dnl
2296 dnl ---------------------------------------------------------------------------
2297 dnl CF_FIX_WARNINGS version: 2 updated: 2020/08/28 15:08:28
2298 dnl ---------------
2299 dnl Warning flags do not belong in CFLAGS, CPPFLAGS, etc.  Any of gcc's
2300 dnl "-Werror" flags can interfere with configure-checks.  Those go into
2301 dnl EXTRA_CFLAGS.
2302 dnl
2303 dnl $1 = variable name to repair
2304 define([CF_FIX_WARNINGS],[
2305 if ( test "$GCC" = yes || test "$GXX" = yes )
2306 then
2307         case [$]$1 in
2308         (*-Werror=*)
2309                 CF_VERBOSE(repairing $1: [$]$1)
2310                 cf_temp_flags=
2311                 for cf_temp_scan in [$]$1
2312                 do
2313                         case "x$cf_temp_scan" in
2314                         (x-Werror=*)
2315                                 CF_APPEND_TEXT(EXTRA_CFLAGS,"$cf_temp_scan")
2316                                 ;;
2317                         (*)
2318                                 CF_APPEND_TEXT(cf_temp_flags,"$cf_temp_scan")
2319                                 ;;
2320                         esac
2321                 done
2322                 $1="$cf_temp_flags"
2323                 CF_VERBOSE(... fixed [$]$1)
2324                 CF_VERBOSE(... extra $EXTRA_CFLAGS)
2325                 ;;
2326         esac
2327 fi
2328 AC_SUBST(EXTRA_CFLAGS)
2329 ])dnl
2330 dnl ---------------------------------------------------------------------------
2331 dnl CF_FOPEN_BIN_R version: 2 updated: 2019/12/31 08:53:54
2332 dnl --------------
2333 dnl Check if fopen works when the "b" (binary) flag is added to the mode
2334 dnl parameter.  POSIX ignores the "b", which c89 specified.  Some very old
2335 dnl systems do not accept it.
2336 AC_DEFUN([CF_FOPEN_BIN_R],[
2337 AC_CACHE_CHECK(if fopen accepts explicit binary mode,cf_cv_fopen_bin_r,[
2338         AC_TRY_RUN([
2339 #include <stdio.h>
2340 int main(void) {
2341         FILE *fp = fopen("conftest.tmp", "wb");
2342         int rc = 0;
2343         if (fp != 0) {
2344                 int p, q;
2345                 for (p = 0; p < 256; ++p) {
2346                         fputc(p, fp);
2347                 }
2348                 fclose(fp);
2349                 fp = fopen("conftest.tmp", "rb");
2350                 if (fp != 0) {
2351                         for (p = 0; p < 256; ++p) {
2352                                 q = fgetc(fp);
2353                                 if (q != p) {
2354                                         rc = 1;
2355                                         break;
2356                                 }
2357                         }
2358                 } else {
2359                         rc = 1;
2360                 }
2361         } else {
2362                 rc = 1;
2363         }
2364         ${cf_cv_main_return:-return} (rc);
2365 }
2366 ],
2367                 [cf_cv_fopen_bin_r=yes],
2368                 [cf_cv_fopen_bin_r=no],
2369                 [cf_cv_fopen_bin_r=unknown])
2370 ])
2371 test "x$cf_cv_fopen_bin_r" != xno && AC_DEFINE(USE_FOPEN_BIN_R,1,[Define to 1 if fopen accepts explicit binary mode])
2372 ])dnl
2373 dnl ---------------------------------------------------------------------------
2374 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
2375 dnl --------------
2376 dnl Forget that we saw the given tool.
2377 AC_DEFUN([CF_FORGET_TOOL],[
2378 unset ac_cv_prog_ac_ct_$1
2379 unset ac_ct_$1
2380 unset $1
2381 ])dnl
2382 dnl ---------------------------------------------------------------------------
2383 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
2384 dnl -------------
2385 dnl Test for dlsym() and related functions, as well as libdl.
2386 dnl
2387 dnl Sets
2388 dnl     $cf_have_dlsym
2389 dnl     $cf_have_libdl
2390 AC_DEFUN([CF_FUNC_DLSYM],[
2391 cf_have_dlsym=no
2392 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
2393
2394 cf_have_libdl=no
2395 AC_CHECK_LIB(dl,dlsym,[
2396         cf_have_dlsym=yes
2397         cf_have_libdl=yes])])
2398
2399 if test "$cf_have_dlsym" = yes ; then
2400         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
2401
2402         AC_MSG_CHECKING(whether able to link to dl*() functions)
2403         AC_TRY_LINK([#include <dlfcn.h>],[
2404                 void *obj;
2405                 if ((obj = dlopen("filename", 0)) != 0) {
2406                         if (dlsym(obj, "symbolname") == 0) {
2407                         dlclose(obj);
2408                         }
2409                 }],[
2410                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
2411                 AC_MSG_ERROR(Cannot link test program for libdl)])
2412         AC_MSG_RESULT(ok)
2413 else
2414         AC_MSG_ERROR(Cannot find dlsym function)
2415 fi
2416 ])
2417 dnl ---------------------------------------------------------------------------
2418 dnl CF_FUNC_MEMMOVE version: 9 updated: 2017/01/21 11:06:25
2419 dnl ---------------
2420 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
2421 dnl is found, add our own version of memmove to the list of objects.
2422 AC_DEFUN([CF_FUNC_MEMMOVE],
2423 [
2424 AC_CHECK_FUNC(memmove,,[
2425 AC_CHECK_FUNC(bcopy,[
2426         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
2427                 AC_TRY_RUN([
2428 int main(void) {
2429         static char data[] = "abcdefghijklmnopqrstuwwxyz";
2430         char temp[40];
2431         bcopy(data, temp, sizeof(data));
2432         bcopy(temp+10, temp, 15);
2433         bcopy(temp+5, temp+15, 10);
2434         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
2435 }
2436                 ],
2437                 [cf_cv_good_bcopy=yes],
2438                 [cf_cv_good_bcopy=no],
2439                 [cf_cv_good_bcopy=unknown])
2440                 ])
2441         ],[cf_cv_good_bcopy=no])
2442         if test "$cf_cv_good_bcopy" = yes ; then
2443                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
2444         else
2445                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
2446         fi
2447 ])])dnl
2448 dnl ---------------------------------------------------------------------------
2449 dnl CF_FUNC_NANOSLEEP version: 5 updated: 2017/01/21 11:06:25
2450 dnl -----------------
2451 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
2452 dnl AIX 4.x, provide a non-working version.
2453 AC_DEFUN([CF_FUNC_NANOSLEEP],[
2454 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
2455 AC_TRY_RUN([
2456 #include <stdio.h>
2457 #include <errno.h>
2458 #include <time.h>
2459
2460 #ifdef HAVE_SYS_TIME_H
2461 #include <sys/time.h>
2462 #endif
2463
2464 int main(void) {
2465         struct timespec ts1, ts2;
2466         int code;
2467         ts1.tv_sec  = 0;
2468         ts1.tv_nsec = 750000000;
2469         ts2.tv_sec  = 0;
2470         ts2.tv_nsec = 0;
2471         errno = 0;
2472         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
2473         ${cf_cv_main_return:-return}(code != 0);
2474 }
2475 ],
2476         [cf_cv_func_nanosleep=yes],
2477         [cf_cv_func_nanosleep=no],
2478         [cf_cv_func_nanosleep=unknown])])
2479
2480 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
2481 ])
2482 dnl ---------------------------------------------------------------------------
2483 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
2484 dnl ---------------
2485 dnl Check for openpty() function, along with <pty.h> header.  It may need the
2486 dnl "util" library as well.
2487 AC_DEFUN([CF_FUNC_OPENPTY],
2488 [
2489 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
2490 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
2491         cf_save_LIBS="$LIBS"
2492         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
2493         for cf_header in pty.h libutil.h util.h
2494         do
2495         AC_TRY_LINK([
2496 #include <$cf_header>
2497 ],[
2498         int x = openpty((int *)0, (int *)0, (char *)0,
2499                                    (struct termios *)0, (struct winsize *)0);
2500 ],[
2501                 cf_cv_func_openpty=$cf_header
2502                 break
2503 ],[
2504                 cf_cv_func_openpty=no
2505 ])
2506         done
2507         LIBS="$cf_save_LIBS"
2508 ])
2509 ])dnl
2510 dnl ---------------------------------------------------------------------------
2511 dnl CF_FUNC_POLL version: 9 updated: 2015/10/10 13:27:32
2512 dnl ------------
2513 dnl See if the poll function really works.  Some platforms have poll(), but
2514 dnl it does not work for terminals or files.
2515 AC_DEFUN([CF_FUNC_POLL],[
2516 tty 2>&1 >/dev/null || { AC_CHECK_FUNCS(posix_openpt) }
2517 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2518 AC_TRY_RUN([
2519 #include <stdlib.h>
2520 #include <stdio.h>
2521 #include <unistd.h>
2522 #include <fcntl.h>
2523 #ifdef HAVE_POLL_H
2524 #include <poll.h>
2525 #else
2526 #include <sys/poll.h>
2527 #endif
2528 int main(void) {
2529         struct pollfd myfds;
2530         int ret;
2531
2532         /* check for Darwin bug with respect to "devices" */
2533         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2534         if (myfds.fd < 0)
2535                 myfds.fd = 0;
2536         myfds.events = POLLIN;
2537         myfds.revents = 0;
2538
2539         ret = poll(&myfds, 1, 100);
2540
2541         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2542                 ret = -1;
2543         } else {
2544                 int fd = 0;
2545                 if (!isatty(fd)) {
2546                         fd = open("/dev/tty", 2);       /* O_RDWR */
2547                 }
2548 #ifdef HAVE_POSIX_OPENPT
2549                 if (fd < 0) {
2550                         fd = posix_openpt(O_RDWR);
2551                 }
2552 #endif
2553
2554                 if (fd >= 0) {
2555                         /* also check with standard input */
2556                         myfds.fd = fd;
2557                         myfds.events = POLLIN;
2558                         myfds.revents = 0;
2559                         ret = poll(&myfds, 1, 100);
2560                 } else {
2561                         ret = -1;
2562                 }
2563         }
2564         ${cf_cv_main_return:-return}(ret < 0);
2565 }],
2566         [cf_cv_working_poll=yes],
2567         [cf_cv_working_poll=no],
2568         [cf_cv_working_poll=unknown])])
2569 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2570 ])dnl
2571 dnl ---------------------------------------------------------------------------
2572 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2573 dnl ---------------
2574 dnl Some old/broken variations define tcgetattr() only as a macro in
2575 dnl termio(s).h
2576 AC_DEFUN([CF_FUNC_TERMIOS],[
2577 AC_REQUIRE([CF_STRUCT_TERMIOS])
2578 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2579 AC_TRY_LINK([
2580 #include <sys/types.h>
2581 #ifdef HAVE_UNISTD_H
2582 #include <unistd.h>
2583 #endif
2584 #ifdef HAVE_TERMIOS_H
2585 #include <termios.h>
2586 #define TTY struct termios
2587 #else
2588 #ifdef HAVE_TERMIO_H
2589 #include <termio.h>
2590 #define TTY struct termio
2591 #endif
2592 #endif
2593 ],[
2594 TTY foo;
2595 tcgetattr(1, &foo);],
2596 [cf_cv_have_tcgetattr=yes],
2597 [cf_cv_have_tcgetattr=no])])
2598 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2599 ])dnl
2600 dnl ---------------------------------------------------------------------------
2601 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
2602 dnl ---------------
2603 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2604 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2605 dnl other functions.
2606 AC_DEFUN([CF_FUNC_VSSCANF],
2607 [
2608 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2609 AC_TRY_LINK([
2610 #include <stdarg.h>
2611 #include <stdio.h>],[
2612         va_list ap;
2613         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2614 AC_TRY_LINK([
2615 #include <stdarg.h>
2616 #include <stdio.h>],[
2617         FILE strbuf;
2618         char *str = "from";
2619
2620         strbuf._flag = _IOREAD;
2621         strbuf._ptr = strbuf._base = (unsigned char *) str;
2622         strbuf._cnt = strlen(str);
2623         strbuf._file = _NFILE;
2624         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2625 AC_TRY_LINK([
2626 #include <stdarg.h>
2627 #include <stdio.h>],[
2628         FILE strbuf;
2629         char *str = "from";
2630
2631         strbuf._flag = _IOREAD;
2632         strbuf._ptr = strbuf._base = (unsigned char *) str;
2633         strbuf._cnt = strlen(str);
2634         strbuf._file = _NFILE;
2635         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2636 cf_cv_func_vsscanf=no])])])])
2637
2638 case $cf_cv_func_vsscanf in
2639 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2640 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2641 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2642 esac
2643
2644 ])dnl
2645 dnl ---------------------------------------------------------------------------
2646 dnl CF_GCC_ATTRIBUTES version: 19 updated: 2020/08/29 09:05:21
2647 dnl -----------------
2648 dnl Test for availability of useful gcc __attribute__ directives to quiet
2649 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2650 dnl to documentation, unrecognized directives cause older compilers to barf.
2651 AC_DEFUN([CF_GCC_ATTRIBUTES],
2652 [
2653 if ( test "$GCC" = yes || test "$GXX" = yes )
2654 then
2655 cat > conftest.i <<EOF
2656 #ifndef GCC_PRINTF
2657 #define GCC_PRINTF 0
2658 #endif
2659 #ifndef GCC_SCANF
2660 #define GCC_SCANF 0
2661 #endif
2662 #ifndef GCC_NORETURN
2663 #define GCC_NORETURN /* nothing */
2664 #endif
2665 #ifndef GCC_UNUSED
2666 #define GCC_UNUSED /* nothing */
2667 #endif
2668 EOF
2669 if test "$GCC" = yes
2670 then
2671         AC_CHECKING([for $CC __attribute__ directives])
2672 cat > conftest.$ac_ext <<EOF
2673 #line __oline__ "${as_me:-configure}"
2674 #include "confdefs.h"
2675 #include "conftest.h"
2676 #include "conftest.i"
2677 #if     GCC_PRINTF
2678 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2679 #else
2680 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2681 #endif
2682 #if     GCC_SCANF
2683 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2684 #else
2685 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2686 #endif
2687 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2688 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
2689 extern void foo(void) GCC_NORETURN;
2690 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
2691 EOF
2692         cf_printf_attribute=no
2693         cf_scanf_attribute=no
2694         for cf_attribute in scanf printf unused noreturn
2695         do
2696                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2697                 cf_directive="__attribute__(($cf_attribute))"
2698                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2699
2700                 case $cf_attribute in
2701                 (printf)
2702                         cf_printf_attribute=yes
2703                         cat >conftest.h <<EOF
2704 #define GCC_$cf_ATTRIBUTE 1
2705 EOF
2706                         ;;
2707                 (scanf)
2708                         cf_scanf_attribute=yes
2709                         cat >conftest.h <<EOF
2710 #define GCC_$cf_ATTRIBUTE 1
2711 EOF
2712                         ;;
2713                 (*)
2714                         cat >conftest.h <<EOF
2715 #define GCC_$cf_ATTRIBUTE $cf_directive
2716 EOF
2717                         ;;
2718                 esac
2719
2720                 if AC_TRY_EVAL(ac_compile); then
2721                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2722                         cat conftest.h >>confdefs.h
2723                         case $cf_attribute in
2724                         (noreturn)
2725                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2726                                 ;;
2727                         (printf)
2728                                 cf_value='/* nothing */'
2729                                 if test "$cf_printf_attribute" != no ; then
2730                                         cf_value='__attribute__((format(printf,fmt,var)))'
2731                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2732                                 fi
2733                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2734                                 ;;
2735                         (scanf)
2736                                 cf_value='/* nothing */'
2737                                 if test "$cf_scanf_attribute" != no ; then
2738                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2739                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2740                                 fi
2741                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2742                                 ;;
2743                         (unused)
2744                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2745                                 ;;
2746                         esac
2747                 fi
2748         done
2749 else
2750         fgrep define conftest.i >>confdefs.h
2751 fi
2752 rm -rf conftest*
2753 fi
2754 ])dnl
2755 dnl ---------------------------------------------------------------------------
2756 dnl CF_GCC_VERSION version: 8 updated: 2019/09/07 13:38:36
2757 dnl --------------
2758 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
2759 dnl compatible), attempt to determine if icc/clang is actually used.
2760 AC_DEFUN([CF_GCC_VERSION],[
2761 AC_REQUIRE([AC_PROG_CC])
2762 GCC_VERSION=none
2763 if test "$GCC" = yes ; then
2764         AC_MSG_CHECKING(version of $CC)
2765         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2766         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2767         AC_MSG_RESULT($GCC_VERSION)
2768 fi
2769 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2770 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2771 ])dnl
2772 dnl ---------------------------------------------------------------------------
2773 dnl CF_GCC_WARNINGS version: 38 updated: 2020/08/28 15:08:28
2774 dnl ---------------
2775 dnl Check if the compiler supports useful warning options.  There's a few that
2776 dnl we don't use, simply because they're too noisy:
2777 dnl
2778 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2779 dnl     -Winline (usually not worthwhile)
2780 dnl     -Wredundant-decls (system headers make this too noisy)
2781 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2782 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2783 dnl             is enabled for ncurses using "--enable-const".
2784 dnl     -pedantic
2785 dnl
2786 dnl Parameter:
2787 dnl     $1 is an optional list of gcc warning flags that a particular
2788 dnl             application might want to use, e.g., "no-unused" for
2789 dnl             -Wno-unused
2790 dnl Special:
2791 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2792 dnl
2793 AC_DEFUN([CF_GCC_WARNINGS],
2794 [
2795 AC_REQUIRE([CF_GCC_VERSION])
2796 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
2797 cat > conftest.$ac_ext <<EOF
2798 #line __oline__ "${as_me:-configure}"
2799 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2800 EOF
2801 if test "$INTEL_COMPILER" = yes
2802 then
2803 # The "-wdXXX" options suppress warnings:
2804 # remark #1419: external declaration in primary source file
2805 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2806 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2807 # remark #193: zero used for undefined preprocessing identifier
2808 # remark #593: variable "curs_sb_left_arrow" was set but never used
2809 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2810 # remark #869: parameter "tw" was never referenced
2811 # remark #981: operands are evaluated in unspecified order
2812 # warning #279: controlling expression is constant
2813
2814         AC_CHECKING([for $CC warning options])
2815         cf_save_CFLAGS="$CFLAGS"
2816         EXTRA_CFLAGS="$EXTRA_CFLAGS -Wall"
2817         for cf_opt in \
2818                 wd1419 \
2819                 wd1683 \
2820                 wd1684 \
2821                 wd193 \
2822                 wd593 \
2823                 wd279 \
2824                 wd810 \
2825                 wd869 \
2826                 wd981
2827         do
2828                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2829                 if AC_TRY_EVAL(ac_compile); then
2830                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2831                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2832                 fi
2833         done
2834         CFLAGS="$cf_save_CFLAGS"
2835 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
2836 then
2837         AC_CHECKING([for $CC warning options])
2838         cf_save_CFLAGS="$CFLAGS"
2839         cf_warn_CONST=""
2840         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2841         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2842         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2843         for cf_opt in W Wall \
2844                 Wbad-function-cast \
2845                 Wcast-align \
2846                 Wcast-qual \
2847                 Wdeclaration-after-statement \
2848                 Wextra \
2849                 Winline \
2850                 Wmissing-declarations \
2851                 Wmissing-prototypes \
2852                 Wnested-externs \
2853                 Wpointer-arith \
2854                 Wshadow \
2855                 Wstrict-prototypes \
2856                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
2857         do
2858                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2859                 if AC_TRY_EVAL(ac_compile); then
2860                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2861                         case $cf_opt in
2862                         (Winline)
2863                                 case $GCC_VERSION in
2864                                 ([[34]].*)
2865                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2866                                         continue;;
2867                                 esac
2868                                 ;;
2869                         (Wpointer-arith)
2870                                 case $GCC_VERSION in
2871                                 ([[12]].*)
2872                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2873                                         continue;;
2874                                 esac
2875                                 ;;
2876                         esac
2877                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2878                 fi
2879         done
2880         CFLAGS="$cf_save_CFLAGS"
2881 fi
2882 rm -rf conftest*
2883
2884 AC_SUBST(EXTRA_CFLAGS)
2885 ])dnl
2886 dnl ---------------------------------------------------------------------------
2887 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2888 dnl ----------------
2889 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2890 dnl unistd.h or (nonstandard) in getopt.h
2891 AC_DEFUN([CF_GETOPT_HEADER],
2892 [
2893 AC_HAVE_HEADERS(unistd.h getopt.h)
2894 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2895 cf_cv_getopt_header=none
2896 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2897 do
2898 AC_TRY_COMPILE([
2899 #include <$cf_header>],
2900 [int x = optind; char *y = optarg],
2901 [cf_cv_getopt_header=$cf_header
2902  break])
2903 done
2904 ])
2905 if test $cf_cv_getopt_header != none ; then
2906         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2907 fi
2908 if test $cf_cv_getopt_header = getopt.h ; then
2909         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2910 fi
2911 ])dnl
2912 dnl ---------------------------------------------------------------------------
2913 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2914 dnl -----------------
2915 AC_DEFUN([CF_GNATPREP_OPT_T],[
2916 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2917 cf_cv_gnatprep_opt_t=no
2918 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2919 ])
2920 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2921 AC_SUBST(GNATPREP_OPTS)
2922 ])dnl
2923 dnl ---------------------------------------------------------------------------
2924 dnl CF_GNAT_GENERICS version: 6 updated: 2020/07/04 19:30:27
2925 dnl ----------------
2926 AC_DEFUN([CF_GNAT_GENERICS],
2927 [
2928 AC_REQUIRE([CF_GNAT_VERSION])
2929
2930 AC_MSG_CHECKING(if GNAT supports generics)
2931 case $cf_cv_gnat_version in
2932 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
2933         cf_gnat_generics=yes
2934         ;;
2935 (*)
2936         cf_gnat_generics=no
2937         ;;
2938 esac
2939 AC_MSG_RESULT($cf_gnat_generics)
2940
2941 if test "$cf_gnat_generics" = yes
2942 then
2943         cf_compile_generics=generics
2944         cf_generic_objects="\${GENOBJS}"
2945 else
2946         cf_compile_generics=
2947         cf_generic_objects=
2948 fi
2949
2950 AC_SUBST(cf_compile_generics)
2951 AC_SUBST(cf_generic_objects)
2952 ])dnl
2953 dnl ---------------------------------------------------------------------------
2954 dnl CF_GNAT_PROJECTS version: 10 updated: 2019/12/31 08:53:54
2955 dnl ----------------
2956 dnl GNAT projects are configured with ".gpr" project files.
2957 dnl GNAT libraries are a further development, using the project feature.
2958 AC_DEFUN([CF_GNAT_PROJECTS],
2959 [
2960 AC_REQUIRE([CF_GNAT_VERSION])
2961 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2962
2963 cf_gnat_libraries=no
2964 cf_gnat_projects=no
2965
2966 if test "$enable_gnat_projects" != no ; then
2967 AC_MSG_CHECKING(if GNAT supports project files)
2968 case $cf_cv_gnat_version in
2969 (3.[[0-9]]*)
2970         ;;
2971 (*)
2972         case $cf_cv_system_name in
2973         (cygwin*|msys*)
2974                 ;;
2975         (*)
2976                 rm -rf conftest* *~conftest*
2977                 if mkdir conftest.src conftest.bin conftest.lib
2978                 then
2979                         cd conftest.src
2980                         rm -rf conftest* *~conftest*
2981                         cat >>library.gpr <<CF_EOF
2982 project Library is
2983   Kind := External ("LIB_KIND");
2984   for Library_Name use "ConfTest";
2985   for Object_Dir use ".";
2986   for Library_ALI_Dir use External("LIBRARY_DIR");
2987   for Library_Version use External ("SONAME");
2988   for Library_Kind use Kind;
2989   for Library_Dir use External("BUILD_DIR");
2990   Source_Dir := External ("SOURCE_DIR");
2991   for Source_Dirs use (Source_Dir);
2992 end Library;
2993 CF_EOF
2994                         cat >>confpackage.ads <<CF_EOF
2995 package ConfPackage is
2996    procedure conftest;
2997 end ConfPackage;
2998 CF_EOF
2999                         cat >>confpackage.adb <<CF_EOF
3000 with Text_IO;
3001 package body ConfPackage is
3002    procedure conftest is
3003    begin
3004       Text_IO.Put ("Hello World");
3005       Text_IO.New_Line;
3006    end conftest;
3007 end ConfPackage;
3008 CF_EOF
3009                         if ( $cf_ada_make $ADAFLAGS \
3010                                         -Plibrary.gpr \
3011                                         -XBUILD_DIR=`cd ../conftest.bin;pwd` \
3012                                         -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
3013                                         -XSOURCE_DIR=`pwd` \
3014                                         -XSONAME=libConfTest.so.1 \
3015                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
3016                                 cf_gnat_projects=yes
3017                         fi
3018                         cd ..
3019                 fi
3020                 if test -f conftest.lib/confpackage.ali
3021                 then
3022                         cf_gnat_libraries=yes
3023                 fi
3024                 rm -rf conftest* *~conftest*
3025                 ;;
3026         esac
3027         ;;
3028 esac
3029 AC_MSG_RESULT($cf_gnat_projects)
3030 fi # enable_gnat_projects
3031
3032 if test $cf_gnat_projects = yes
3033 then
3034         AC_MSG_CHECKING(if GNAT supports libraries)
3035         AC_MSG_RESULT($cf_gnat_libraries)
3036 fi
3037
3038 if test "$cf_gnat_projects" = yes
3039 then
3040         USE_OLD_MAKERULES="#"
3041         USE_GNAT_PROJECTS=""
3042 else
3043         USE_OLD_MAKERULES=""
3044         USE_GNAT_PROJECTS="#"
3045 fi
3046
3047 if test "$cf_gnat_libraries" = yes
3048 then
3049         USE_GNAT_LIBRARIES=""
3050 else
3051         USE_GNAT_LIBRARIES="#"
3052 fi
3053
3054 AC_SUBST(USE_OLD_MAKERULES)
3055 AC_SUBST(USE_GNAT_PROJECTS)
3056 AC_SUBST(USE_GNAT_LIBRARIES)
3057 ])dnl
3058 dnl ---------------------------------------------------------------------------
3059 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
3060 dnl --------------
3061 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
3062 dnl is noted that gnat may compile a tasking unit even for configurations which
3063 dnl fail at runtime.
3064 AC_DEFUN([CF_GNAT_SIGINT],[
3065 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
3066 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
3067
3068 package ConfTest is
3069
3070    pragma Warnings (Off);  --  the next pragma exists since 3.11p
3071    pragma Unreserve_All_Interrupts;
3072    pragma Warnings (On);
3073
3074    protected Process is
3075       procedure Stop;
3076       function Continue return Boolean;
3077       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
3078    private
3079       Done : Boolean := False;
3080    end Process;
3081
3082 end ConfTest;],
3083 [package body ConfTest is
3084    protected body Process is
3085       procedure Stop is
3086       begin
3087          Done := True;
3088       end Stop;
3089       function Continue return Boolean is
3090       begin
3091          return not Done;
3092       end Continue;
3093    end Process;
3094 end ConfTest;],
3095         [cf_cv_gnat_sigint=yes],
3096         [cf_cv_gnat_sigint=no])])
3097
3098 if test $cf_cv_gnat_sigint = yes ; then
3099         USE_GNAT_SIGINT=""
3100 else
3101         USE_GNAT_SIGINT="#"
3102 fi
3103 AC_SUBST(USE_GNAT_SIGINT)
3104 ])dnl
3105 dnl ---------------------------------------------------------------------------
3106 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
3107 dnl ----------------
3108 dnl Verify that a test program compiles/links with GNAT.
3109 dnl $cf_ada_make is set to the program that compiles/links
3110 dnl $ADAFLAGS may be set to the GNAT flags.
3111 dnl
3112 dnl $1 is the text of the spec
3113 dnl $2 is the text of the body
3114 dnl $3 is the shell command to execute if successful
3115 dnl $4 is the shell command to execute if not successful
3116 AC_DEFUN([CF_GNAT_TRY_LINK],
3117 [
3118 rm -rf conftest* *~conftest*
3119 cat >>conftest.ads <<CF_EOF
3120 $1
3121 CF_EOF
3122 cat >>conftest.adb <<CF_EOF
3123 $2
3124 CF_EOF
3125 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3126 ifelse($3,,      :,[      $3])
3127 ifelse($4,,,[else
3128    $4])
3129 fi
3130 rm -rf conftest* *~conftest*
3131 ])dnl
3132 dnl ---------------------------------------------------------------------------
3133 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
3134 dnl ---------------
3135 dnl Verify that a test program compiles and runs with GNAT
3136 dnl $cf_ada_make is set to the program that compiles/links
3137 dnl $ADAFLAGS may be set to the GNAT flags.
3138 dnl
3139 dnl $1 is the text of the spec
3140 dnl $2 is the text of the body
3141 dnl $3 is the shell command to execute if successful
3142 dnl $4 is the shell command to execute if not successful
3143 AC_DEFUN([CF_GNAT_TRY_RUN],
3144 [
3145 rm -rf conftest* *~conftest*
3146 cat >>conftest.ads <<CF_EOF
3147 $1
3148 CF_EOF
3149 cat >>conftest.adb <<CF_EOF
3150 $2
3151 CF_EOF
3152 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3153    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
3154 ifelse($3,,      :,[      $3])
3155 ifelse($4,,,[   else
3156       $4])
3157    fi
3158 ifelse($4,,,[else
3159    $4])
3160 fi
3161 rm -rf conftest* *~conftest*
3162 ])dnl
3163 dnl ---------------------------------------------------------------------------
3164 dnl CF_GNAT_VERSION version: 22 updated: 2019/12/31 08:53:54
3165 dnl ---------------
3166 dnl $1 = cache variable to update
3167 dnl $2 = program name
3168 dnl Verify version of GNAT or related tool
3169 AC_DEFUN([CF_GNAT_VERSION],
3170 [
3171 AC_CACHE_CHECK(for ifelse($2,,gnat,$2) version, cf_cv_gnat_version,[
3172 cf_cv_gnat_version=`ifelse($2,,${cf_ada_make:-gnatmake},$2) --version 2>&1 | \
3173         grep '[[0-9]].[[0-9]][[0-9]]*' |\
3174         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
3175 ])
3176 test -z "$cf_cv_gnat_version" && cf_cv_gnat_version=no
3177 ifelse($1,,,[eval $1=$cf_cv_gnat_version; unset cf_cv_gnat_version])
3178 ])dnl
3179 dnl ---------------------------------------------------------------------------
3180 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
3181 dnl -------------
3182 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
3183 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
3184 dnl (or misfeature) of glibc2, which breaks portability of many applications,
3185 dnl since it is interwoven with GNU extensions.
3186 dnl
3187 dnl Well, yes we could work around it...
3188 dnl
3189 dnl Parameters:
3190 dnl     $1 is the nominal value for _XOPEN_SOURCE
3191 AC_DEFUN([CF_GNU_SOURCE],
3192 [
3193 cf_gnu_xopen_source=ifelse($1,,500,$1)
3194
3195 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
3196 AC_TRY_COMPILE([#include <sys/types.h>],[
3197         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
3198                 return 0;
3199         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
3200                 return 0;
3201         #else
3202         #       error not GNU C library
3203         #endif],
3204         [cf_cv_gnu_library=yes],
3205         [cf_cv_gnu_library=no])
3206 ])
3207
3208 if test x$cf_cv_gnu_library = xyes; then
3209
3210         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
3211         # was changed to help a little.  newlib incorporated the change about 4
3212         # years later.
3213         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
3214                 cf_save="$CPPFLAGS"
3215                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3216                 AC_TRY_COMPILE([#include <sys/types.h>],[
3217                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
3218                                 return 0;
3219                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
3220                                 return 0;
3221                         #else
3222                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
3223                         #endif],
3224                         [cf_cv_gnu_library_219=yes],
3225                         [cf_cv_gnu_library_219=no])
3226                 CPPFLAGS="$cf_save"
3227         ])
3228
3229         if test "x$cf_cv_gnu_library_219" = xyes; then
3230                 cf_save="$CPPFLAGS"
3231                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
3232                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
3233                         AC_TRY_COMPILE([
3234                                 #include <limits.h>
3235                                 #include <sys/types.h>
3236                                 ],[
3237                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
3238                                         return 0;
3239                                 #else
3240                                 #       error GNU C library is too old
3241                                 #endif],
3242                                 [cf_cv_gnu_dftsrc_219=yes],
3243                                 [cf_cv_gnu_dftsrc_219=no])
3244                         ])
3245                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
3246         else
3247                 cf_cv_gnu_dftsrc_219=maybe
3248         fi
3249
3250         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
3251
3252                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
3253                 AC_TRY_COMPILE([#include <sys/types.h>],[
3254                         #ifndef _XOPEN_SOURCE
3255                         #error  expected _XOPEN_SOURCE to be defined
3256                         #endif],
3257                         [cf_cv_gnu_source=no],
3258                         [cf_save="$CPPFLAGS"
3259                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
3260                          AC_TRY_COMPILE([#include <sys/types.h>],[
3261                                 #ifdef _XOPEN_SOURCE
3262                                 #error  expected _XOPEN_SOURCE to be undefined
3263                                 #endif],
3264                                 [cf_cv_gnu_source=no],
3265                                 [cf_cv_gnu_source=yes])
3266                         CPPFLAGS="$cf_save"
3267                         ])
3268                 ])
3269
3270                 if test "$cf_cv_gnu_source" = yes
3271                 then
3272                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
3273                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
3274                         AC_TRY_COMPILE([#include <sys/types.h>],[
3275                                 #ifdef _DEFAULT_SOURCE
3276                                 #error  expected _DEFAULT_SOURCE to be undefined
3277                                 #endif],
3278                                 [cf_cv_default_source=no],
3279                                 [cf_cv_default_source=yes])
3280                         ])
3281                         if test "$cf_cv_default_source" = yes
3282                         then
3283                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3284                         fi
3285                 fi
3286         fi
3287
3288 fi
3289 ])dnl
3290 dnl ---------------------------------------------------------------------------
3291 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
3292 dnl --------------
3293 dnl If we're trying to use g++, test if libg++ is installed (a rather common
3294 dnl problem :-).  If we have the compiler but no library, we'll be able to
3295 dnl configure, but won't be able to build the c++ demo program.
3296 AC_DEFUN([CF_GPP_LIBRARY],
3297 [
3298 cf_cxx_library=unknown
3299 case $cf_cv_system_name in
3300 (os2*)
3301         cf_gpp_libname=gpp
3302         ;;
3303 (*)
3304         cf_gpp_libname=g++
3305         ;;
3306 esac
3307 if test "$GXX" = yes; then
3308         AC_MSG_CHECKING([for lib$cf_gpp_libname])
3309         cf_save="$LIBS"
3310         CF_ADD_LIB($cf_gpp_libname)
3311         AC_TRY_LINK([
3312 #include <$cf_gpp_libname/builtin.h>
3313         ],
3314         [two_arg_error_handler_t foo2 = lib_error_handler],
3315         [cf_cxx_library=yes
3316          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3317          if test "$cf_gpp_libname" = cpp ; then
3318             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
3319          else
3320             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
3321          fi],
3322         [AC_TRY_LINK([
3323 #include <builtin.h>
3324         ],
3325         [two_arg_error_handler_t foo2 = lib_error_handler],
3326         [cf_cxx_library=yes
3327          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3328          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
3329         [cf_cxx_library=no])])
3330         LIBS="$cf_save"
3331         AC_MSG_RESULT($cf_cxx_library)
3332 fi
3333 ])dnl
3334 dnl ---------------------------------------------------------------------------
3335 dnl CF_GXX_VERSION version: 8 updated: 2017/02/11 14:48:57
3336 dnl --------------
3337 dnl Check for version of g++
3338 AC_DEFUN([CF_GXX_VERSION],[
3339 AC_REQUIRE([AC_PROG_CPP])
3340 GXX_VERSION=none
3341 if test "$GXX" = yes; then
3342         AC_MSG_CHECKING(version of ${CXX:-g++})
3343         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
3344         if test -z "$GXX_VERSION"
3345         then
3346                 GXX_VERSION=unknown
3347                 GXX=no
3348         fi
3349         AC_MSG_RESULT($GXX_VERSION)
3350 fi
3351 ])dnl
3352 dnl ---------------------------------------------------------------------------
3353 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
3354 dnl ---------------
3355 dnl Check if the compiler supports useful warning options.
3356 dnl
3357 dnl Most of gcc's options apply to g++, except:
3358 dnl     -Wbad-function-cast
3359 dnl     -Wmissing-declarations
3360 dnl     -Wnested-externs
3361 dnl
3362 dnl Omit a few (for now):
3363 dnl     -Winline
3364 dnl
3365 dnl Parameter:
3366 dnl     $1 is an optional list of g++ warning flags that a particular
3367 dnl             application might want to use, e.g., "no-unused" for
3368 dnl             -Wno-unused
3369 dnl Special:
3370 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
3371 dnl
3372 AC_DEFUN([CF_GXX_WARNINGS],
3373 [
3374
3375 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
3376 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
3377
3378 AC_REQUIRE([CF_GXX_VERSION])
3379
3380 AC_LANG_SAVE
3381 AC_LANG_CPLUSPLUS
3382
3383 cat > conftest.$ac_ext <<EOF
3384 #line __oline__ "configure"
3385 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
3386 EOF
3387
3388 if test "$INTEL_CPLUSPLUS" = yes
3389 then
3390 # The "-wdXXX" options suppress warnings:
3391 # remark #1419: external declaration in primary source file
3392 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3393 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3394 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
3395 # remark #193: zero used for undefined preprocessing identifier
3396 # remark #593: variable "curs_sb_left_arrow" was set but never used
3397 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
3398 # remark #869: parameter "tw" was never referenced
3399 # remark #981: operands are evaluated in unspecified order
3400 # warning #269: invalid format string conversion
3401
3402         AC_CHECKING([for $CC warning options])
3403         cf_save_CXXFLAGS="$CXXFLAGS"
3404         EXTRA_CXXFLAGS="-Wall"
3405         for cf_opt in \
3406                 wd1419 \
3407                 wd1682 \
3408                 wd1683 \
3409                 wd1684 \
3410                 wd193 \
3411                 wd279 \
3412                 wd593 \
3413                 wd810 \
3414                 wd869 \
3415                 wd981
3416         do
3417                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
3418                 if AC_TRY_EVAL(ac_compile); then
3419                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3420                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3421                 fi
3422         done
3423         CXXFLAGS="$cf_save_CXXFLAGS"
3424
3425 elif test "$GXX" = yes
3426 then
3427         AC_CHECKING([for $CXX warning options])
3428         cf_save_CXXFLAGS="$CXXFLAGS"
3429         EXTRA_CXXFLAGS="-W -Wall"
3430         cf_gxx_extra_warnings=""
3431         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
3432         case "$GCC_VERSION" in
3433         ([[1-2]].*)
3434                 ;;
3435         (*)
3436                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
3437                 ;;
3438         esac
3439         for cf_opt in \
3440                 Wabi \
3441                 fabi-version=0 \
3442                 Wextra \
3443                 Wignored-qualifiers \
3444                 Wlogical-op \
3445                 Woverloaded-virtual \
3446                 Wsign-promo \
3447                 Wsynth \
3448                 Wold-style-cast \
3449                 Wcast-align \
3450                 Wcast-qual \
3451                 Wpointer-arith \
3452                 Wshadow \
3453                 Wundef $cf_gxx_extra_warnings $1
3454         do
3455                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
3456                 if AC_TRY_EVAL(ac_compile); then
3457                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3458                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3459                 else
3460                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
3461                 fi
3462         done
3463         CXXFLAGS="$cf_save_CXXFLAGS"
3464 fi
3465
3466 rm -rf conftest*
3467 AC_LANG_RESTORE
3468 AC_SUBST(EXTRA_CXXFLAGS)
3469 ])dnl
3470 dnl ---------------------------------------------------------------------------
3471 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
3472 dnl ------------
3473 dnl Look for an instance of the Berkeley hashed database.
3474 dnl
3475 dnl $1 = optional parameter, to specify install-prefix for the database.
3476 AC_DEFUN([CF_HASHED_DB],
3477 [
3478 ifelse([$1],,,[
3479 case $1 in
3480 (yes|*able*)
3481         ;;
3482 (*)
3483         if test -d "$1" ; then
3484                 CF_ADD_INCDIR($1/include)
3485                 CF_ADD_LIBDIR($1/lib)
3486         else
3487                 case "$1" in
3488                 (./*|../*|/*)
3489                         AC_MSG_WARN(no such directory $1)
3490                         ;;
3491                 (*)
3492                         CF_FIND_SUB_INCDIR($1)
3493                         CF_FIND_SUB_LIBDIR($1)
3494                         ;;
3495                 esac
3496         fi
3497 esac
3498 ])
3499 AC_CHECK_HEADER(db.h,[
3500 CF_HASHED_DB_VERSION
3501 if test "$cf_cv_hashed_db_version" = unknown ; then
3502         AC_MSG_ERROR(Cannot determine version of db)
3503 else
3504         CF_HASHED_DB_LIBS
3505         if test "$cf_cv_hashed_db_libs" = unknown ; then
3506                 AC_MSG_ERROR(Cannot determine library for db)
3507         elif test "$cf_cv_hashed_db_libs" != default ; then
3508                 CF_ADD_LIB($cf_cv_hashed_db_libs)
3509         fi
3510 fi
3511 ],[
3512         AC_MSG_ERROR(Cannot find db.h)
3513 ])
3514 ])dnl
3515 dnl ---------------------------------------------------------------------------
3516 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
3517 dnl -----------------
3518 dnl Given that we have the header and version for hashed database, find the
3519 dnl library information.
3520 AC_DEFUN([CF_HASHED_DB_LIBS],
3521 [
3522 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
3523 cf_cv_hashed_db_libs=unknown
3524 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
3525 do
3526         cf_save_libs="$LIBS"
3527         if test -n "$cf_db_libs"; then
3528                 CF_ADD_LIB($cf_db_libs)
3529         fi
3530         CF_MSG_LOG(checking for library "$cf_db_libs")
3531         AC_TRY_LINK([
3532 $ac_includes_default
3533 #include <db.h>
3534 ],[
3535         char *path = "/tmp/foo";
3536 #ifdef DB_VERSION_MAJOR
3537 #if DB_VERSION_MAJOR >= 4
3538         DB *result = 0;
3539         db_create(&result, NULL, 0);
3540         result->open(result,
3541                 NULL,
3542                 path,
3543                 path,
3544                 DB_HASH,
3545                 DB_CREATE,
3546                 0644);
3547 #elif DB_VERSION_MAJOR >= 3
3548         DB *result = 0;
3549         db_create(&result, NULL, 0);
3550         result->open(result,
3551                 path,
3552                 path,
3553                 DB_HASH,
3554                 DB_CREATE,
3555                 0644);
3556 #elif DB_VERSION_MAJOR >= 2
3557         DB *result = 0;
3558         db_open(path,
3559                 DB_HASH,
3560                 DB_CREATE,
3561                 0644,
3562                 (DB_ENV *) 0,
3563                 (DB_INFO *) 0,
3564                 &result);
3565 #endif /* DB_VERSION_MAJOR */
3566 #else
3567         DB *result = dbopen(path,
3568                      2,
3569                      0644,
3570                      DB_HASH,
3571                      0);
3572 #endif
3573         ${cf_cv_main_return:-return}(result != 0)
3574 ],[
3575         if test -n "$cf_db_libs" ; then
3576                 cf_cv_hashed_db_libs=$cf_db_libs
3577         else
3578                 cf_cv_hashed_db_libs=default
3579         fi
3580         LIBS="$cf_save_libs"
3581         break
3582 ])
3583         LIBS="$cf_save_libs"
3584 done
3585 ])
3586 ])dnl
3587 dnl ---------------------------------------------------------------------------
3588 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3589 dnl --------------------
3590 dnl Given that we have the header file for hashed database, find the version
3591 dnl information.
3592 AC_DEFUN([CF_HASHED_DB_VERSION],
3593 [
3594 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3595 cf_cv_hashed_db_version=unknown
3596
3597 for cf_db_version in 1 2 3 4 5 6
3598 do
3599         CF_MSG_LOG(checking for db version $cf_db_version)
3600         AC_TRY_COMPILE([
3601 $ac_includes_default
3602 #include <db.h>
3603
3604 #ifdef DB_VERSION_MAJOR
3605         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3606 #if $cf_db_version == DB_VERSION_MAJOR
3607         /* ok */
3608 #else
3609         make an error
3610 #endif
3611 #else
3612 #if $cf_db_version == 1
3613         /* ok: assuming this is DB 1.8.5 */
3614 #else
3615         make an error
3616 #endif
3617 #endif
3618 ],[DBT *foo = 0],[
3619         cf_cv_hashed_db_version=$cf_db_version
3620         break
3621         ])
3622 done
3623 ])
3624 ])dnl
3625 dnl ---------------------------------------------------------------------------
3626 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
3627 dnl --------------
3628 dnl Construct a search-list of directories for a nonstandard header-file
3629 dnl
3630 dnl Parameters
3631 dnl     $1 = the variable to return as result
3632 dnl     $2 = the package name
3633 AC_DEFUN([CF_HEADER_PATH],
3634 [
3635 $1=
3636
3637 # collect the current set of include-directories from compiler flags
3638 cf_header_path_list=""
3639 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3640         for cf_header_path in $CPPFLAGS $CFLAGS
3641         do
3642                 case $cf_header_path in
3643                 (-I*)
3644                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3645                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3646                         cf_header_path_list="$cf_header_path_list [$]$1"
3647                         ;;
3648                 esac
3649         done
3650 fi
3651
3652 # add the variations for the package we are looking for
3653 CF_SUBDIR_PATH($1,$2,include)
3654
3655 test "$includedir" != NONE && \
3656 test "$includedir" != "/usr/include" && \
3657 test -d "$includedir" && {
3658         test -d $includedir &&    $1="[$]$1 $includedir"
3659         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
3660 }
3661
3662 test "$oldincludedir" != NONE && \
3663 test "$oldincludedir" != "/usr/include" && \
3664 test -d "$oldincludedir" && {
3665         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
3666         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
3667 }
3668
3669 $1="[$]$1 $cf_header_path_list"
3670 ])dnl
3671 dnl ---------------------------------------------------------------------------
3672 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
3673 dnl ---------------
3674 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3675 AC_DEFUN([CF_HELP_MESSAGE],
3676 [CF_ACVERSION_CHECK(2.53,[],[
3677 AC_DIVERT_HELP($1)])dnl
3678 ])dnl
3679 dnl ---------------------------------------------------------------------------
3680 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3681 dnl ---------------
3682 dnl Construct the list of include-options according to whether we're building
3683 dnl in the source directory or using '--srcdir=DIR' option.
3684 AC_DEFUN([CF_INCLUDE_DIRS],
3685 [
3686 if test "$srcdir" != "."; then
3687         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3688 fi
3689 CPPFLAGS="-I../include $CPPFLAGS"
3690 if test "$srcdir" != "."; then
3691         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3692 fi
3693 CPPFLAGS="-I. $CPPFLAGS"
3694 AC_SUBST(CPPFLAGS)
3695 ])dnl
3696 dnl ---------------------------------------------------------------------------
3697 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
3698 dnl ---------------
3699 dnl prompt for/fill-in useful install-program options
3700 AC_DEFUN([CF_INSTALL_OPTS],
3701 [
3702 CF_INSTALL_OPT_S
3703 CF_INSTALL_OPT_P
3704 CF_INSTALL_OPT_O
3705 ])dnl
3706 dnl ---------------------------------------------------------------------------
3707 dnl CF_INSTALL_OPT_O version: 2 updated: 2015/05/15 19:45:35
3708 dnl ----------------
3709 dnl Almost all "install" programs default to the current user's ownership.
3710 dnl Almost - MINIX is an exception.
3711 AC_DEFUN([CF_INSTALL_OPT_O],
3712 [
3713 AC_MSG_CHECKING(if install needs to be told about ownership)
3714 case `$ac_config_guess` in
3715 (*minix)
3716         with_install_o=yes
3717         ;;
3718 (*)
3719         with_install_o=no
3720         ;;
3721 esac
3722
3723 AC_MSG_RESULT($with_install_o)
3724 if test "x$with_install_o" = xyes
3725 then
3726         INSTALL_OPT_O=`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`
3727 else
3728         INSTALL_OPT_O=
3729 fi
3730
3731 AC_SUBST(INSTALL_OPT_O)
3732 ])dnl
3733 dnl ---------------------------------------------------------------------------
3734 dnl CF_INSTALL_OPT_P version: 1 updated: 2018/08/18 12:19:21
3735 dnl ----------------
3736 dnl Some install-programs accept a "-p" option to preserve file modification
3737 dnl timestamps.  That can be useful as an install option, as well as a way to
3738 dnl avoid the need for ranlib after copying a static archive.
3739 AC_DEFUN([CF_INSTALL_OPT_P],
3740 [
3741 : ${INSTALL:=install}
3742 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
3743         rm -rf conftest*
3744         date >conftest.in
3745         mkdir conftest.out
3746         sleep 3
3747         if $INSTALL -p conftest.in conftest.out 2>/dev/null
3748         then
3749                 if test -f conftest.out/conftest.in
3750                 then
3751                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
3752                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
3753                         if test -s conftest.err
3754                         then
3755                                 cf_cv_install_p=no
3756                         else
3757                                 cf_cv_install_p=yes
3758                         fi
3759                 else
3760                         cf_cv_install_p=no
3761                 fi
3762         else
3763                 cf_cv_install_p=no
3764         fi
3765         rm -rf conftest*
3766 ])
3767 ])dnl
3768 dnl ---------------------------------------------------------------------------
3769 dnl CF_INSTALL_OPT_S version: 2 updated: 2018/08/18 12:19:21
3770 dnl ----------------
3771 dnl By default, we should strip executables which are installed, but leave the
3772 dnl ability to suppress that for unit-testing.
3773 AC_DEFUN([CF_INSTALL_OPT_S],
3774 [
3775 AC_MSG_CHECKING(if you want to install stripped executables)
3776 CF_ARG_DISABLE(stripping,
3777         [  --disable-stripping     do not strip (debug info) installed executables],
3778         [with_stripping=no],
3779         [with_stripping=yes])
3780 AC_MSG_RESULT($with_stripping)
3781
3782 if test "$with_stripping" = yes
3783 then
3784         INSTALL_OPT_S="-s"
3785 else
3786         INSTALL_OPT_S=
3787 fi
3788 AC_SUBST(INSTALL_OPT_S)
3789 ])dnl
3790 dnl ---------------------------------------------------------------------------
3791 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
3792 dnl -----------------
3793 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3794 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3795 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3796 dnl
3797 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3798 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3799 dnl the wrappers for gcc and g++ warnings.
3800 dnl
3801 dnl $1 = GCC (default) or GXX
3802 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3803 dnl $3 = CFLAGS (default) or CXXFLAGS
3804 AC_DEFUN([CF_INTEL_COMPILER],[
3805 AC_REQUIRE([AC_CANONICAL_HOST])
3806 ifelse([$2],,INTEL_COMPILER,[$2])=no
3807
3808 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3809         case $host_os in
3810         (linux*|gnu*)
3811                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3812                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3813                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3814                 AC_TRY_COMPILE([],[
3815 #ifdef __INTEL_COMPILER
3816 #else
3817 make an error
3818 #endif
3819 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3820 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3821 ],[])
3822                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3823                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3824                 ;;
3825         esac
3826 fi
3827 ])dnl
3828 dnl ---------------------------------------------------------------------------
3829 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3830 dnl ----------
3831 dnl Check if we have either a function or macro for 'isascii()'.
3832 AC_DEFUN([CF_ISASCII],
3833 [
3834 AC_MSG_CHECKING(for isascii)
3835 AC_CACHE_VAL(cf_cv_have_isascii,[
3836         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3837         [cf_cv_have_isascii=yes],
3838         [cf_cv_have_isascii=no])
3839 ])dnl
3840 AC_MSG_RESULT($cf_cv_have_isascii)
3841 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3842 ])dnl
3843 dnl ---------------------------------------------------------------------------
3844 dnl CF_LARGEFILE version: 12 updated: 2020/03/19 20:23:48
3845 dnl ------------
3846 dnl Add checks for large file support.
3847 AC_DEFUN([CF_LARGEFILE],[
3848 ifdef([AC_FUNC_FSEEKO],[
3849         AC_SYS_LARGEFILE
3850         if test "$enable_largefile" != no ; then
3851         AC_FUNC_FSEEKO
3852
3853         # Normally we would collect these definitions in the config.h,
3854         # but (like _XOPEN_SOURCE), some environments rely on having these
3855         # defined before any of the system headers are included.  Another
3856         # case comes up with C++, e.g., on AIX the compiler compiles the
3857         # header files by themselves before looking at the body files it is
3858         # told to compile.  For ncurses, those header files do not include
3859         # the config.h
3860         if test "$ac_cv_sys_large_files" != no
3861         then
3862                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
3863         fi
3864         if test "$ac_cv_sys_largefile_source" != no
3865         then
3866                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
3867         fi
3868         if test "$ac_cv_sys_file_offset_bits" != no
3869         then
3870                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
3871         fi
3872
3873         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3874                 AC_TRY_COMPILE([
3875 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
3876 #include <sys/types.h>
3877 #include <dirent.h>
3878                 ],[
3879                 /* if transitional largefile support is setup, this is true */
3880                 extern struct dirent64 * readdir(DIR *);
3881                 struct dirent64 *x = readdir((DIR *)0);
3882                 struct dirent *y = readdir((DIR *)0);
3883                 int z = x - y;
3884                 (void)z;
3885                 ],
3886                 [cf_cv_struct_dirent64=yes],
3887                 [cf_cv_struct_dirent64=no])
3888         ])
3889         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3890         fi
3891 ])
3892 ])
3893 dnl ---------------------------------------------------------------------------
3894 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3895 dnl -----------------
3896 dnl Check for compiler/linker flags used to temporarily force usage of static
3897 dnl libraries.  This depends on the compiler and platform.  Use this to help
3898 dnl ensure that the linker picks up a given library based on its position in
3899 dnl the list of linker options and libraries.
3900 AC_DEFUN([CF_LDFLAGS_STATIC],[
3901
3902 if test "$GCC" = yes ; then
3903         case $cf_cv_system_name in
3904         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3905                 LDFLAGS_STATIC=
3906                 LDFLAGS_SHARED=
3907                 ;;
3908         (*)     # normally, except when broken
3909                 LDFLAGS_STATIC=-static
3910                 LDFLAGS_SHARED=-dynamic
3911                 ;;
3912         esac
3913 else
3914         case $cf_cv_system_name in
3915         (aix[[4-7]]*)   # from ld manpage
3916                 LDFLAGS_STATIC=-bstatic
3917                 LDFLAGS_SHARED=-bdynamic
3918                 ;;
3919         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3920                 # We could also use just "archive" and "shared".
3921                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3922                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3923                 ;;
3924         (irix*)         # from ld manpage IRIX64
3925                 LDFLAGS_STATIC=-Bstatic
3926                 LDFLAGS_SHARED=-Bdynamic
3927                 ;;
3928         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3929                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3930                 LDFLAGS_STATIC=-noso
3931                 LDFLAGS_SHARED=-so_archive
3932                 ;;
3933         (solaris2*)
3934                 LDFLAGS_STATIC=-Bstatic
3935                 LDFLAGS_SHARED=-Bdynamic
3936                 ;;
3937         esac
3938 fi
3939
3940 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3941 then
3942         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3943
3944         rm -f libconftest.a
3945         cat >conftest.$ac_ext <<EOF
3946 #line __oline__ "configure"
3947 #include <stdio.h>
3948 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3949 EOF
3950         if AC_TRY_EVAL(ac_compile) ; then
3951                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3952                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3953         fi
3954         rm -f conftest.*
3955
3956         cf_save_LIBS="$LIBS"
3957
3958         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3959         AC_TRY_LINK([
3960 #line __oline__ "configure"
3961 #include <stdio.h>
3962 int cf_ldflags_static(FILE *fp);
3963 ],[
3964         return cf_ldflags_static(stdin);
3965 ],[
3966         # some linkers simply ignore the -dynamic
3967         case x`file conftest$ac_exeext 2>/dev/null` in
3968         (*static*)
3969                 cf_ldflags_static=no
3970                 ;;
3971         (*)
3972                 cf_ldflags_static=yes
3973                 ;;
3974         esac
3975 ],[cf_ldflags_static=no])
3976
3977         rm -f libconftest.*
3978         LIBS="$cf_save_LIBS"
3979
3980         AC_MSG_RESULT($cf_ldflags_static)
3981
3982         if test $cf_ldflags_static != yes
3983         then
3984                 LDFLAGS_STATIC=
3985                 LDFLAGS_SHARED=
3986         fi
3987 else
3988         LDFLAGS_STATIC=
3989         LDFLAGS_SHARED=
3990 fi
3991
3992 AC_SUBST(LDFLAGS_STATIC)
3993 AC_SUBST(LDFLAGS_SHARED)
3994 ])
3995 dnl ---------------------------------------------------------------------------
3996 dnl CF_LD_RPATH_OPT version: 8 updated: 2018/08/18 16:36:35
3997 dnl ---------------
3998 dnl For the given system and compiler, find the compiler flags to pass to the
3999 dnl loader to use the "rpath" feature.
4000 AC_DEFUN([CF_LD_RPATH_OPT],
4001 [
4002 AC_REQUIRE([CF_CHECK_CACHE])
4003
4004 LD_RPATH_OPT=
4005 if test "x$cf_cv_enable_rpath" != xno
4006 then
4007         AC_MSG_CHECKING(for an rpath option)
4008         case $cf_cv_system_name in
4009         (irix*)
4010                 if test "$GCC" = yes; then
4011                         LD_RPATH_OPT="-Wl,-rpath,"
4012                 else
4013                         LD_RPATH_OPT="-rpath "
4014                 fi
4015                 ;;
4016         (linux*|gnu*|k*bsd*-gnu|freebsd*)
4017                 LD_RPATH_OPT="-Wl,-rpath,"
4018                 ;;
4019         (openbsd[[2-9]].*|mirbsd*)
4020                 LD_RPATH_OPT="-Wl,-rpath,"
4021                 ;;
4022         (dragonfly*)
4023                 LD_RPATH_OPT="-rpath "
4024                 ;;
4025         (netbsd*)
4026                 LD_RPATH_OPT="-Wl,-rpath,"
4027                 ;;
4028         (osf*|mls+*)
4029                 LD_RPATH_OPT="-rpath "
4030                 ;;
4031         (solaris2*)
4032                 LD_RPATH_OPT="-R"
4033                 ;;
4034         (*)
4035                 ;;
4036         esac
4037         AC_MSG_RESULT($LD_RPATH_OPT)
4038
4039         case "x$LD_RPATH_OPT" in
4040         (x-R*)
4041                 AC_MSG_CHECKING(if we need a space after rpath option)
4042                 cf_save_LIBS="$LIBS"
4043                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
4044                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
4045                 LIBS="$cf_save_LIBS"
4046                 AC_MSG_RESULT($cf_rpath_space)
4047                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
4048                 ;;
4049         esac
4050 fi
4051 ])dnl
4052 dnl ---------------------------------------------------------------------------
4053 dnl CF_LD_SEARCHPATH version: 2 updated: 2019/09/26 20:34:14
4054 dnl ----------------
4055 dnl Try to obtain the linker's search-path, for use in scripts.
4056 dnl
4057 dnl Ignore LD_LIBRARY_PATH, etc.
4058 AC_DEFUN([CF_LD_SEARCHPATH],[
4059 AC_CACHE_CHECK(for linker search path,cf_cv_ld_searchpath,[
4060
4061 if test "$cross_compiling" != yes ; then
4062
4063 # GNU binutils' ld does not involve permissions which may stop ldconfig.
4064 cf_pathlist=`ld --verbose 2>/dev/null | grep SEARCH_DIR | sed -e 's,SEARCH_DIR[[("=]][[("=]]*,,g' -e 's/"[[)]];//gp' | sort -u`
4065
4066 # The -NX options tell newer versions of Linux ldconfig to not attempt to
4067 # update the cache, which makes it run faster.
4068 test -z "$cf_pathlist" && \
4069         cf_pathlist=`ldconfig -NX -v 2>/dev/null | sed -e '/^[[         ]]/d' -e 's/:$//' | sort -u`
4070
4071 test -z "$cf_pathlist" &&
4072         cf_pathlist=`ldconfig -v 2>/dev/null | sed -n -e '/^[[  ]]/d' -e 's/:$//p' | sort -u`
4073
4074 # This works with OpenBSD 6.5, which lists only filenames
4075 test -z "$cf_pathlist" &&
4076         cf_pathlist=`ldconfig -v 2>/dev/null | sed -n -e 's,^Adding \(.*\)/.*[$],\1,p' | sort -u`
4077
4078 if test -z "$cf_pathlist"
4079 then
4080         # dyld default path with MacOS
4081         if test -f /usr/bin/otool && test "x`uname -s`" = xDarwin
4082         then
4083                 # do this to bypass check
4084                 cf_cv_ld_searchpath='$HOME/lib'
4085                 cf_pathlist="/usr/local/lib /lib /usr/lib"
4086         fi
4087 fi
4088
4089 if test -z "$cf_pathlist"
4090 then
4091         # Solaris is hardcoded
4092         if test -d /opt/SUNWspro/lib
4093         then
4094                 cf_pathlist="/opt/SUNWspro/lib /usr/ccs/lib /usr/lib"
4095         elif test -d /usr/ccs/lib
4096         then
4097                 cf_pathlist="/usr/ccs/lib /usr/lib"
4098         fi
4099 fi
4100
4101 fi
4102
4103 # If nothing else, assume it is conventional
4104 test -z "$cf_pathlist" && cf_pathlist="/usr/lib /lib"
4105
4106 # Finally, check that this is only directories
4107 for cf_path in [$]0 $cf_pathlist
4108 do
4109         if test -d "$cf_path"; then
4110                 test -n "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath="${cf_cv_ld_searchpath} "
4111                 cf_cv_ld_searchpath="${cf_cv_ld_searchpath}${cf_path}"
4112         fi
4113 done
4114
4115 # Ensure that it is nonempty
4116 test -z "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath=/usr/lib
4117 ])
4118
4119 LD_SEARCHPATH=`echo "$cf_cv_ld_searchpath"|sed -e 's/ /|/g'`
4120 AC_SUBST(LD_SEARCHPATH)
4121 ])dnl
4122 dnl ---------------------------------------------------------------------------
4123 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
4124 dnl ---------------
4125 dnl Construct a search-list of directories for a nonstandard library-file
4126 dnl
4127 dnl Parameters
4128 dnl     $1 = the variable to return as result
4129 dnl     $2 = the package name
4130 AC_DEFUN([CF_LIBRARY_PATH],
4131 [
4132 $1=
4133 cf_library_path_list=""
4134 if test -n "${LDFLAGS}${LIBS}" ; then
4135         for cf_library_path in $LDFLAGS $LIBS
4136         do
4137                 case $cf_library_path in
4138                 (-L*)
4139                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
4140                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
4141                         cf_library_path_list="$cf_library_path_list [$]$1"
4142                         ;;
4143                 esac
4144         done
4145 fi
4146
4147 CF_SUBDIR_PATH($1,$2,lib)
4148
4149 $1="$cf_library_path_list [$]$1"
4150 ])dnl
4151 dnl ---------------------------------------------------------------------------
4152 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
4153 dnl ------------------
4154 AC_DEFUN([CF_LIBTOOL_VERSION],[
4155 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
4156 then
4157         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
4158 else
4159         cf_cv_libtool_version=
4160 fi
4161 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
4162 ])dnl
4163 dnl ---------------------------------------------------------------------------
4164 dnl CF_LIB_PREFIX version: 13 updated: 2020/04/04 10:11:47
4165 dnl -------------
4166 dnl Compute the library-prefix for the given host system
4167 dnl $1 = variable to set
4168 define([CF_LIB_PREFIX],
4169 [
4170         case $cf_cv_system_name in
4171         (OS/2*|os2*)
4172                 if test "$DFT_LWR_MODEL" = libtool; then
4173                         LIB_PREFIX='lib'
4174                 else
4175                         LIB_PREFIX=''
4176                 fi
4177                 ;;
4178         (*-msvc*)
4179                 LIB_PREFIX=''
4180                 ;;
4181         (*)     LIB_PREFIX='lib'
4182                 ;;
4183         esac
4184 ifelse($1,,,[$1=$LIB_PREFIX])
4185         AC_SUBST(LIB_PREFIX)
4186 ])dnl
4187 dnl ---------------------------------------------------------------------------
4188 dnl CF_LIB_RULES version: 90 updated: 2020/04/04 10:11:47
4189 dnl ------------
4190 dnl Append definitions and rules for the given models to the subdirectory
4191 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
4192 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
4193 dnl the corresponding makefile to list the models that we'll generate.
4194 dnl
4195 dnl For shared libraries, make a list of symbolic links to construct when
4196 dnl generating each library.  The convention used for Linux is the simplest
4197 dnl one:
4198 dnl     lib<name>.so    ->
4199 dnl     lib<name>.so.<major>    ->
4200 dnl     lib<name>.so.<maj>.<minor>
4201 dnl
4202 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
4203 AC_DEFUN([CF_LIB_RULES],
4204 [
4205 cf_prefix=$LIB_PREFIX
4206 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
4207
4208 case $cf_cv_shlib_version in
4209 (cygdll|msysdll|mingw|msvcdll)
4210         TINFO_NAME=$TINFO_ARG_SUFFIX
4211         TINFO_SUFFIX=.dll
4212         ;;
4213 esac
4214
4215 if test -n "$TINFO_SUFFIX" ; then
4216         case $TINFO_SUFFIX in
4217         (tw*)
4218                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
4219                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
4220                 ;;
4221         (t*)
4222                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
4223                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
4224                 ;;
4225         (w*)
4226                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
4227                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
4228                 ;;
4229         esac
4230 fi
4231
4232 for cf_dir in $SRC_SUBDIRS
4233 do
4234         if test ! -d $srcdir/$cf_dir ; then
4235                 continue
4236         elif test -f $srcdir/$cf_dir/modules; then
4237
4238                 SHARED_LIB=
4239                 Libs_To_Make=
4240                 cf_awk_program=
4241                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
4242                 then
4243                         cf_awk_program="$cf_awk_program\
4244 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
4245 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
4246 "
4247                 fi
4248
4249                 if test "x$WILDCARD_SYMS" = xno
4250                 then
4251                         cf_awk_program="$cf_awk_program\
4252 /[[     ]]_\\*;/ { skip=1; next; }\
4253 "
4254                 fi
4255
4256                 if test "x$cf_awk_program" != "x"
4257                 then
4258                         cat >>$cf_dir/Makefile <<CF_EOF
4259
4260 # Generated by CF_LIB_RULES
4261 resulting.map: $UNALTERED_SYMS
4262         $AWK 'BEGIN { skip = 1; last=""; } \
4263 $cf_awk_program \
4264 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
4265  skip = 0; last = \[$]\[$]0; } \
4266 END { print last; }' < $UNALTERED_SYMS >\[$]@
4267
4268 distclean::
4269         rm -f resulting.map
4270 CF_EOF
4271                 fi
4272
4273                 for cf_item in $cf_LIST_MODELS
4274                 do
4275                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4276                         if test "$cf_dir" = "c++"
4277                         then
4278                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4279                         else
4280                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4281                         fi
4282                         test -z "$cf_libname" && cf_libname="$cf_dir"
4283                         if test $cf_item = shared ; then
4284                                 if test -n "${LIB_SUFFIX}"
4285                                 then
4286                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4287                                 else
4288                                         cf_shared_suffix="$cf_suffix"
4289                                 fi
4290                                 if test "$cf_cv_do_symlinks" = yes ; then
4291                                         cf_version_name=
4292
4293                                         case "$cf_cv_shlib_version" in
4294                                         (rel)
4295                                                 cf_version_name=REL_VERSION
4296                                                 ;;
4297                                         (abi)
4298                                                 cf_version_name=ABI_VERSION
4299                                                 ;;
4300                                         esac
4301
4302                                         if test -n "$cf_version_name"
4303                                         then
4304                                                 case "$cf_cv_system_name" in
4305                                                 (darwin*)
4306                                                         # "w", etc?
4307                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
4308                                                         ;;
4309                                                 (*)
4310                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
4311                                                         ;;
4312                                                 esac
4313                                         fi
4314                                         if test -n "${USE_LIB_SUFFIX}"
4315                                         then
4316                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4317                                         else
4318                                                 cf_shared_suffix="$cf_suffix"
4319                                         fi
4320                                 fi
4321                                 # cygwin needs import library, and has unique naming convention
4322                                 # use autodetected ${cf_prefix} for import lib and static lib, but
4323                                 # use 'cyg' prefix for shared lib.
4324                                 case $cf_cv_shlib_version in
4325                                 (cygdll)
4326                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4327                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
4328                                         ;;
4329                                 (msysdll)
4330                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4331                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
4332                                         ;;
4333                                 (mingw)
4334                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4335                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
4336                                         ;;
4337                                 (msvcdll)
4338                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4339                                         cf_add_lib="../lib/${cf_libname}${cf_cygsuf}"
4340                                         ;;
4341                                 (*)
4342                                         cf_add_lib=
4343                                         ;;
4344                                 esac
4345                                 if test -n "$cf_add_lib"
4346                                 then
4347                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4348                                         continue
4349                                 fi
4350                         fi
4351                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
4352                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4353                 done
4354
4355                 if test $cf_dir = ncurses ; then
4356                         cf_subsets="$LIB_SUBSETS"
4357                         cf_r_parts="$cf_subsets"
4358                         cf_liblist="$Libs_To_Make"
4359
4360                         while test -n "$cf_r_parts"
4361                         do
4362                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
4363                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
4364                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
4365                                         cf_add_lib=
4366                                         case $cf_l_parts in
4367                                         (*termlib*)
4368                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
4369                                                 ;;
4370                                         (*ticlib*)
4371                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
4372                                                 ;;
4373                                         (*)
4374                                                 break
4375                                                 ;;
4376                                         esac
4377                                         if test -n "$cf_add_lib"; then
4378                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
4379                                         fi
4380                                 else
4381                                         break
4382                                 fi
4383                         done
4384                 else
4385                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
4386                 fi
4387
4388                 if test $cf_dir = c++; then
4389                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
4390                                 cf_list=
4391                                 for cf_item in $Libs_To_Make
4392                                 do
4393                                         case $cf_item in
4394                                         (*.a)
4395                                                 ;;
4396                                         (*)
4397                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
4398                                                 ;;
4399                                         esac
4400                                         for cf_test in $cf_list
4401                                         do
4402                                                 if test "$cf_test" = "$cf_item"
4403                                                 then
4404                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
4405                                                         cf_item=
4406                                                         break
4407                                                 fi
4408                                         done
4409                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
4410                                 done
4411                                 Libs_To_Make="$cf_list"
4412                         fi
4413                 fi
4414
4415                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
4416                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
4417                         $cf_dir/Makefile >$cf_dir/Makefile.out
4418                 mv $cf_dir/Makefile.out $cf_dir/Makefile
4419
4420                 $AWK -f $srcdir/mk-0th.awk \
4421                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
4422                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4423
4424                 for cf_subset in $cf_subsets
4425                 do
4426                         cf_subdirs=
4427                         for cf_item in $cf_LIST_MODELS
4428                         do
4429
4430                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
4431                         CF_UPPER(cf_ITEM,$cf_item)
4432
4433                         CXX_MODEL=$cf_ITEM
4434                         if test "$CXX_MODEL" = SHARED; then
4435                                 case $cf_cv_shlib_version in
4436                                 (cygdll|msysdll|mingw|msvcdll)
4437                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
4438                                         with_shared_cxx=yes
4439                                         ;;
4440                                 (*)
4441                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
4442                                         ;;
4443                                 esac
4444                         fi
4445
4446                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4447                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
4448
4449                         # Test for case where we build libtinfo with a different name.
4450                         cf_libname=$cf_dir
4451                         if test $cf_dir = ncurses ; then
4452                                 case $cf_subset in
4453                                 (*base*)
4454                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
4455                                         ;;
4456                                 (*termlib*)
4457                                         cf_libname=$TINFO_LIB_SUFFIX
4458                                         ;;
4459                                 (ticlib*)
4460                                         cf_libname=$TICS_LIB_SUFFIX
4461                                         ;;
4462                                 esac
4463                         elif test $cf_dir = c++ ; then
4464                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4465                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4466                         else
4467                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4468                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4469                         fi
4470                         if test -n "${USE_ARG_SUFFIX}" ; then
4471                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
4472                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${USE_LIB_SUFFIX}%%"`
4473                         fi
4474
4475                         # These dependencies really are for development, not
4476                         # builds, but they are useful in porting, too.
4477                         cf_depend="../include/ncurses_cfg.h"
4478                         if test "$srcdir" = "."; then
4479                                 cf_reldir="."
4480                         else
4481                                 cf_reldir="\${srcdir}"
4482                         fi
4483
4484                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
4485                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
4486                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
4487                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
4488                         fi
4489
4490                         cf_dir_suffix=
4491                         old_cf_suffix="$cf_suffix"
4492                         if test "$cf_cv_shlib_version_infix" = yes ; then
4493                         if test -n "$USE_LIB_SUFFIX" ; then
4494                                 case $USE_LIB_SUFFIX in
4495                                 (tw*)
4496                                         cf_libname=`echo $cf_libname | sed 's/tw'$EXTRA_SUFFIX'$//'`
4497                                         cf_suffix=`echo $cf_suffix | sed 's/^tw'$EXTRA_SUFFIX'//'`
4498                                         cf_dir_suffix=tw$EXTRA_SUFFIX
4499                                         ;;
4500                                 (t*)
4501                                         cf_libname=`echo $cf_libname | sed 's/t'$EXTRA_SUFFIX'$//'`
4502                                         cf_suffix=`echo $cf_suffix | sed 's/^t'$EXTRA_SUFFIX'//'`
4503                                         cf_dir_suffix=t$EXTRA_SUFFIX
4504                                         ;;
4505                                 (w*)
4506                                         cf_libname=`echo $cf_libname | sed 's/w'$EXTRA_SUFFIX'$//'`
4507                                         cf_suffix=`echo $cf_suffix | sed 's/^w'$EXTRA_SUFFIX'//'`
4508                                         cf_dir_suffix=w$EXTRA_SUFFIX
4509                                         ;;
4510                                 (*)
4511                                         cf_libname=`echo $cf_libname | sed 's/'$EXTRA_SUFFIX'$//'`
4512                                         cf_suffix=`echo $cf_suffix | sed 's/^'$EXTRA_SUFFIX'//'`
4513                                         cf_dir_suffix=$EXTRA_SUFFIX
4514                                         ;;
4515                                 esac
4516                         fi
4517                         fi
4518
4519                         $AWK -f $srcdir/mk-1st.awk \
4520                                 name=${cf_libname}${cf_dir_suffix} \
4521                                 traces=$LIB_TRACING \
4522                                 MODEL=$cf_ITEM \
4523                                 CXX_MODEL=$CXX_MODEL \
4524                                 model=$cf_subdir \
4525                                 prefix=$cf_prefix \
4526                                 suffix=$cf_suffix \
4527                                 subset=$cf_subset \
4528                                 driver=$cf_cv_term_driver \
4529                                 SymLink="$LN_S" \
4530                                 TermlibRoot=$TINFO_NAME \
4531                                 TermlibSuffix=$TINFO_SUFFIX \
4532                                 ShlibVer=$cf_cv_shlib_version \
4533                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
4534                                 ReLink=${cf_cv_do_relink:-no} \
4535                                 ReRanlib=${cf_cv_do_reranlib:-yes} \
4536                                 DoLinks=$cf_cv_do_symlinks \
4537                                 rmSoLocs=$cf_cv_rm_so_locs \
4538                                 ldconfig="$LDCONFIG" \
4539                                 overwrite=$WITH_OVERWRITE \
4540                                 depend="$cf_depend" \
4541                                 host="$host" \
4542                                 libtool_version="$LIBTOOL_VERSION" \
4543                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4544
4545                         cf_suffix="$old_cf_suffix"
4546
4547                         for cf_subdir2 in $cf_subdirs lib
4548                         do
4549                                 test $cf_subdir = $cf_subdir2 && break
4550                         done
4551                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
4552                         $AWK -f $srcdir/mk-2nd.awk \
4553                                 name=$cf_dir \
4554                                 traces=$LIB_TRACING \
4555                                 MODEL=$cf_ITEM \
4556                                 model=$cf_subdir \
4557                                 subset=$cf_subset \
4558                                 srcdir=$srcdir \
4559                                 echo=$WITH_ECHO \
4560                                 crenames=$cf_cv_prog_CC_c_o \
4561                                 cxxrenames=$cf_cv_prog_CXX_c_o \
4562                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4563                         cf_subdirs="$cf_subdirs $cf_subdir"
4564                         done
4565                 done
4566         fi
4567
4568         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
4569 done
4570
4571 for cf_dir in $SRC_SUBDIRS
4572 do
4573         if test ! -d $srcdir/$cf_dir ; then
4574                 continue
4575         fi
4576
4577         if test -f $cf_dir/Makefile ; then
4578                 case "$cf_dir" in
4579                 (Ada95)
4580                         echo 'libs \' >> Makefile
4581                         echo 'install.libs \' >> Makefile
4582                         echo 'uninstall.libs ::' >> Makefile
4583                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
4584                         ;;
4585                 esac
4586         fi
4587
4588         if test -f $srcdir/$cf_dir/modules; then
4589                 echo >> Makefile
4590                 if test -f $srcdir/$cf_dir/headers; then
4591 cat >> Makefile <<CF_EOF
4592 install.includes \\
4593 uninstall.includes \\
4594 CF_EOF
4595                 fi
4596 if test "$cf_dir" != "c++" ; then
4597 echo 'lint \' >> Makefile
4598 fi
4599 cat >> Makefile <<CF_EOF
4600 libs \\
4601 lintlib \\
4602 install.libs \\
4603 uninstall.libs \\
4604 install.$cf_dir \\
4605 uninstall.$cf_dir ::
4606         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
4607 CF_EOF
4608         elif test -f $srcdir/$cf_dir/headers; then
4609 cat >> Makefile <<CF_EOF
4610
4611 libs \\
4612 install.libs \\
4613 uninstall.libs \\
4614 install.includes \\
4615 uninstall.includes ::
4616         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
4617 CF_EOF
4618 fi
4619 done
4620
4621 if test "x$cf_with_db_install" = xyes; then
4622 cat >> Makefile <<CF_EOF
4623
4624 install.libs uninstall.libs \\
4625 install.data uninstall.data ::
4626 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
4627 CF_EOF
4628 else
4629 cat >> Makefile <<CF_EOF
4630
4631 install.libs uninstall.libs ::
4632         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
4633 CF_EOF
4634 fi
4635
4636 if test "x$cf_with_manpages" = xyes; then
4637 cat >> Makefile <<CF_EOF
4638
4639 install.man \\
4640 uninstall.man ::
4641         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
4642 CF_EOF
4643 fi
4644
4645 cat >> Makefile <<CF_EOF
4646
4647 distclean ::
4648         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
4649         rm -f headers.sh headers.sed mk_shared_lib.sh
4650         rm -f edit_man.* man_alias.*
4651         rm -rf \${DIRS_TO_MAKE}
4652 CF_EOF
4653
4654 # Special case: tack's manpage lives in its own directory.
4655 if test "x$cf_with_manpages" = xyes; then
4656 if test "x$cf_with_tack" = "xyes"; then
4657 cat >> Makefile <<CF_EOF
4658
4659 install.man \\
4660 uninstall.man ::
4661         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
4662 CF_EOF
4663 fi
4664 fi
4665
4666 dnl If we're installing into a subdirectory of /usr/include, etc., we should
4667 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
4668 dnl anything, and will make it more standardized.  It's awkward to decide this
4669 dnl at configuration because of quoting, so we'll simply make all headers
4670 dnl installed via a script that can do the right thing.
4671
4672 rm -f headers.sed headers.sh
4673
4674 dnl ( generating this script makes the makefiles a little tidier :-)
4675 echo creating headers.sh
4676 cat >headers.sh <<CF_EOF
4677 #! $SHELL
4678 # This shell script is generated by the 'configure' script.  It is invoked in a
4679 # subdirectory of the build tree.  It generates a sed-script in the parent
4680 # directory that is used to adjust includes for header files that reside in a
4681 # subdirectory of /usr/include, etc.
4682 PRG=""
4683 while test \[$]# != 3
4684 do
4685 PRG="\$PRG \[$]1"; shift
4686 done
4687 DST=\[$]1
4688 REF=\[$]2
4689 SRC=\[$]3
4690 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
4691 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
4692 echo installing \$SRC in \$DST
4693 CF_EOF
4694
4695 if test $WITH_CURSES_H = yes; then
4696         cat >>headers.sh <<CF_EOF
4697 case \$DST in
4698 (/*/include/*)
4699         END=\`basename \$DST\`
4700         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
4701         do
4702                 NAME=\`basename \$i\`
4703                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4704         done
4705         ;;
4706 (*)
4707         echo "" >> \$TMPSED
4708         ;;
4709 esac
4710 CF_EOF
4711
4712 else
4713         cat >>headers.sh <<CF_EOF
4714 case \$DST in
4715 (/*/include/*)
4716         END=\`basename \$DST\`
4717         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
4718         do
4719                 NAME=\`basename \$i\`
4720                 if test "\$NAME" = "curses.h"
4721                 then
4722                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4723                         NAME=ncurses.h
4724                 fi
4725                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4726         done
4727         ;;
4728 (*)
4729         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4730         ;;
4731 esac
4732 CF_EOF
4733 fi
4734 cat >>headers.sh <<CF_EOF
4735 rm -f \$TMPSRC
4736 sed -f \$TMPSED \$SRC > \$TMPSRC
4737 NAME=\`basename \$SRC\`
4738 CF_EOF
4739 if test $WITH_CURSES_H != yes; then
4740         cat >>headers.sh <<CF_EOF
4741 test "\$NAME" = "curses.h" && NAME=ncurses.h
4742 CF_EOF
4743 fi
4744 cat >>headers.sh <<CF_EOF
4745 # Just in case someone gzip'd manpages, remove the conflicting copy.
4746 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
4747
4748 eval \$PRG \$TMPSRC \$DST/\$NAME
4749 rm -f \$TMPSRC \$TMPSED
4750 CF_EOF
4751
4752 chmod 0755 headers.sh
4753
4754 for cf_dir in $SRC_SUBDIRS
4755 do
4756         if test ! -d $srcdir/$cf_dir ; then
4757                 continue
4758         fi
4759
4760         if test -f $srcdir/$cf_dir/headers; then
4761                 $AWK -f $srcdir/mk-hdr.awk \
4762                         subset="$LIB_SUBSETS" \
4763                         compat="$WITH_CURSES_H" \
4764                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
4765         fi
4766
4767         if test -f $srcdir/$cf_dir/modules; then
4768                 if test "$cf_dir" != "c++" ; then
4769                         cat >>$cf_dir/Makefile <<"CF_EOF"
4770 depend : ${AUTO_SRC}
4771         makedepend -- ${CPPFLAGS} -- ${C_SRC}
4772
4773 # DO NOT DELETE THIS LINE -- make depend depends on it.
4774 CF_EOF
4775                 fi
4776         fi
4777 done
4778 AC_SUBST(Libs_To_Make)
4779 ])dnl
4780 dnl ---------------------------------------------------------------------------
4781 dnl CF_LIB_SONAME version: 6 updated: 2017/01/21 11:06:25
4782 dnl -------------
4783 dnl Find the and soname for the given shared library.  Set the cache variable
4784 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
4785 dnl variable to "unknown".
4786 dnl
4787 dnl $1 = headers
4788 dnl $2 = code
4789 dnl $3 = library name
4790 AC_DEFUN([CF_LIB_SONAME],
4791 [
4792 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
4793
4794 cf_cv_$3_soname=unknown
4795 if test "$cross_compiling" != yes ; then
4796 cat >conftest.$ac_ext <<CF_EOF
4797 $1
4798 int main(void)
4799 {
4800 $2
4801         ${cf_cv_main_return:-return}(0);
4802 }
4803 CF_EOF
4804 cf_save_LIBS="$LIBS"
4805         CF_ADD_LIB($3)
4806         if AC_TRY_EVAL(ac_compile) ; then
4807                 if AC_TRY_EVAL(ac_link) ; then
4808                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
4809                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
4810                 fi
4811         fi
4812 rm -rf conftest*
4813 LIBS="$cf_save_LIBS"
4814 fi
4815 ])
4816 ])
4817 dnl ---------------------------------------------------------------------------
4818 dnl CF_LIB_SUFFIX version: 26 updated: 2020/04/04 10:11:47
4819 dnl -------------
4820 dnl Compute the library file-suffix from the given model name
4821 dnl $1 = model name
4822 dnl $2 = variable to set (the nominal library suffix)
4823 dnl $3 = dependency variable to set (actual filename)
4824 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4825 AC_DEFUN([CF_LIB_SUFFIX],
4826 [
4827         case X$1 in
4828         (Xlibtool)
4829                 $2='.la'
4830                 $3=[$]$2
4831                 ;;
4832         (Xdebug)
4833                 case $cf_cv_system_name in
4834                 (*-msvc*)
4835                         $2='_g.lib'
4836                         ;;
4837                 (*)
4838                         $2='_g.a'
4839                         ;;
4840                 esac
4841                 $3=[$]$2
4842                 ;;
4843         (Xprofile)
4844                 case $cf_cv_system_name in
4845                 (*-msvc*)
4846                         $2='_p.lib'
4847                         ;;
4848                 (*)
4849                         $2='_p.a'
4850                         ;;
4851                 esac
4852                 $3=[$]$2
4853                 ;;
4854         (Xshared)
4855                 case $cf_cv_system_name in
4856                 (aix[[5-7]]*)
4857                         $2='.so'
4858                         $3=[$]$2
4859                         ;;
4860                 (*-msvc*)
4861                         $2='.dll'
4862                         $3='.dll.lib'
4863                         ;;
4864                 (cygwin*|msys*|mingw*)
4865                         $2='.dll'
4866                         $3='.dll.a'
4867                         ;;
4868                 (darwin*)
4869                         $2='.dylib'
4870                         $3=[$]$2
4871                         ;;
4872                 (hpux*)
4873                         case $target in
4874                         (ia64*)
4875                                 $2='.so'
4876                                 $3=[$]$2
4877                                 ;;
4878                         (*)
4879                                 $2='.sl'
4880                                 $3=[$]$2
4881                                 ;;
4882                         esac
4883                         ;;
4884                 (*)
4885                         $2='.so'
4886                         $3=[$]$2
4887                         ;;
4888                 esac
4889                 ;;
4890         (*)
4891                 case $target in
4892                 (*-msvc*)
4893                         $2='.lib'
4894                         ;;
4895                 (*)
4896                         $2='.a'
4897                         ;;
4898                 esac
4899                 $3=[$]$2
4900                 ;;
4901         esac
4902         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
4903         then
4904                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
4905                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
4906         fi
4907 ])dnl
4908 dnl ---------------------------------------------------------------------------
4909 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
4910 dnl -----------
4911 dnl Compute the string to append to -library from the given model name
4912 dnl $1 = model name
4913 dnl $2 = variable to set
4914 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4915 AC_DEFUN([CF_LIB_TYPE],
4916 [
4917         case $1 in
4918         (libtool) $2=''   ;;
4919         (normal)  $2=''   ;;
4920         (debug)   $2='_g' ;;
4921         (profile) $2='_p' ;;
4922         (shared)  $2=''   ;;
4923         esac
4924         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
4925 ])dnl
4926 dnl ---------------------------------------------------------------------------
4927 dnl CF_LINK_DATAONLY version: 13 updated: 2020/02/08 15:59:30
4928 dnl ----------------
4929 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
4930 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
4931 dnl have to provide wrappers for global tables to ensure they're linked
4932 dnl properly.
4933 AC_DEFUN([CF_LINK_DATAONLY],
4934 [
4935 AC_MSG_CHECKING([if data-only library module links])
4936 AC_CACHE_VAL(cf_cv_link_dataonly,[
4937         rm -f conftest.a
4938         cat >conftest.$ac_ext <<EOF
4939 #line __oline__ "configure"
4940 int     testdata[[3]] = { 123, 456, 789 };
4941 EOF
4942         if AC_TRY_EVAL(ac_compile) ; then
4943                 mv conftest.o data.o && \
4944                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
4945         fi
4946         rm -f conftest.$ac_ext data.o
4947         cat >conftest.$ac_ext <<EOF
4948 #line __oline__ "configure"
4949 int     testfunc(void)
4950 {
4951 #if defined(NeXT)
4952         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
4953 #else
4954         extern int testdata[[3]];
4955         return testdata[[0]] == 123
4956            &&  testdata[[1]] == 456
4957            &&  testdata[[2]] == 789;
4958 #endif
4959 }
4960 EOF
4961         if AC_TRY_EVAL(ac_compile); then
4962                 mv conftest.o func.o && \
4963                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
4964         fi
4965         rm -f conftest.$ac_ext func.o
4966         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
4967         cf_saveLIBS="$LIBS"
4968         LIBS="conftest.a $LIBS"
4969         AC_TRY_RUN([
4970         int main(void)
4971         {
4972                 extern int testfunc();
4973                 ${cf_cv_main_return:-return} (!testfunc());
4974         }
4975         ],
4976         [cf_cv_link_dataonly=yes],
4977         [cf_cv_link_dataonly=no],
4978         [cf_cv_link_dataonly=unknown])
4979         LIBS="$cf_saveLIBS"
4980         ])
4981 AC_MSG_RESULT($cf_cv_link_dataonly)
4982
4983 if test "$cf_cv_link_dataonly" = no ; then
4984         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
4985         BROKEN_LINKER=1
4986 fi
4987 AC_SUBST(BROKEN_LINKER)
4988
4989 ])dnl
4990 dnl ---------------------------------------------------------------------------
4991 dnl CF_LINK_FUNCS version: 9 updated: 2017/01/21 11:11:02
4992 dnl -------------
4993 dnl Most Unix systems have both link and symlink, a few don't have symlink.
4994 dnl A few non-Unix systems implement symlink, but not link.
4995 dnl A few non-systems implement neither (or have nonfunctional versions).
4996 AC_DEFUN([CF_LINK_FUNCS],
4997 [
4998 AC_CHECK_HEADERS( \
4999 unistd.h \
5000 )
5001 AC_CHECK_FUNCS( \
5002         remove \
5003         unlink )
5004
5005 if test "$cross_compiling" = yes ; then
5006         AC_CHECK_FUNCS( \
5007                 link \
5008                 symlink )
5009 else
5010         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
5011                 cf_cv_link_funcs=
5012                 for cf_func in link symlink ; do
5013                         AC_TRY_RUN([
5014 #include <sys/types.h>
5015 #include <sys/stat.h>
5016 #ifdef HAVE_UNISTD_H
5017 #include <unistd.h>
5018 #endif
5019 int main(void)
5020 {
5021         int fail = 0;
5022         char *src = "config.log";
5023         char *dst = "conftest.chk";
5024         struct stat src_sb;
5025         struct stat dst_sb;
5026
5027         stat(src, &src_sb);
5028         fail = ($cf_func("config.log", "conftest.chk") < 0)
5029             || (stat(dst, &dst_sb) < 0)
5030             || (dst_sb.st_mtime != src_sb.st_mtime);
5031 #ifdef HAVE_UNLINK
5032         unlink(dst);
5033 #else
5034         remove(dst);
5035 #endif
5036         ${cf_cv_main_return:-return} (fail);
5037 }
5038                         ],[
5039                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
5040                         eval 'ac_cv_func_'$cf_func'=yes'],[
5041                         eval 'ac_cv_func_'$cf_func'=no'],[
5042                         eval 'ac_cv_func_'$cf_func'=error'])
5043                 done
5044                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
5045         ])
5046         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
5047         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
5048 fi
5049 ])dnl
5050 dnl ---------------------------------------------------------------------------
5051 dnl CF_MAKEFLAGS version: 18 updated: 2018/02/21 21:26:03
5052 dnl ------------
5053 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
5054 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
5055 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
5056 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
5057 AC_DEFUN([CF_MAKEFLAGS],
5058 [
5059 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
5060         cf_cv_makeflags=''
5061         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
5062         do
5063                 cat >cf_makeflags.tmp <<CF_EOF
5064 SHELL = $SHELL
5065 all :
5066         @ echo '.$cf_option'
5067 CF_EOF
5068                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
5069                 case "$cf_result" in
5070                 (.*k|.*kw)
5071                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
5072                         case "$cf_result" in
5073                         (.*CC=*)        cf_cv_makeflags=
5074                                 ;;
5075                         (*)     cf_cv_makeflags=$cf_option
5076                                 ;;
5077                         esac
5078                         break
5079                         ;;
5080                 (.-)
5081                         ;;
5082                 (*)
5083                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
5084                         ;;
5085                 esac
5086         done
5087         rm -f cf_makeflags.tmp
5088 ])
5089
5090 AC_SUBST(cf_cv_makeflags)
5091 ])dnl
5092 dnl ---------------------------------------------------------------------------
5093 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
5094 dnl ------------
5095 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
5096 dnl a monocase filesystem.
5097 AC_DEFUN([CF_MAKE_TAGS],[
5098 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
5099
5100 AC_CHECK_PROGS(CTAGS, exctags ctags)
5101 AC_CHECK_PROGS(ETAGS, exetags etags)
5102
5103 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
5104
5105 if test "$cf_cv_mixedcase" = yes ; then
5106         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
5107 else
5108         MAKE_UPPER_TAGS=no
5109 fi
5110
5111 if test "$MAKE_UPPER_TAGS" = yes ; then
5112         MAKE_UPPER_TAGS=
5113 else
5114         MAKE_UPPER_TAGS="#"
5115 fi
5116
5117 if test "$MAKE_LOWER_TAGS" = yes ; then
5118         MAKE_LOWER_TAGS=
5119 else
5120         MAKE_LOWER_TAGS="#"
5121 fi
5122
5123 AC_SUBST(CTAGS)
5124 AC_SUBST(ETAGS)
5125
5126 AC_SUBST(MAKE_UPPER_TAGS)
5127 AC_SUBST(MAKE_LOWER_TAGS)
5128 ])dnl
5129 dnl ---------------------------------------------------------------------------
5130 dnl CF_MANPAGE_FORMAT version: 11 updated: 2015/04/18 08:56:57
5131 dnl -----------------
5132 dnl Option to allow user to override automatic configuration of manpage format.
5133 dnl There are several special cases:
5134 dnl
5135 dnl     gzip - man checks for, can display gzip'd files
5136 dnl     compress - man checks for, can display compressed files
5137 dnl     BSDI - files in the cat-directories are suffixed ".0"
5138 dnl     formatted - installer should format (put files in cat-directory)
5139 dnl     catonly - installer should only format, e.g., for a turnkey system.
5140 dnl
5141 dnl There are other configurations which this macro does not test, e.g., HPUX's
5142 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
5143 dnl convention would not match our use).
5144 AC_DEFUN([CF_MANPAGE_FORMAT],
5145 [
5146 AC_REQUIRE([CF_PATHSEP])
5147 AC_MSG_CHECKING(format of man-pages)
5148
5149 AC_ARG_WITH(manpage-format,
5150         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
5151                           optionally formatted/catonly, e.g., gzip,formatted],
5152         [MANPAGE_FORMAT=$withval],
5153         [MANPAGE_FORMAT=unknown])
5154
5155 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
5156 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
5157
5158 cf_unknown=
5159
5160 case $MANPAGE_FORMAT in
5161 (unknown)
5162         if test -z "$MANPATH" ; then
5163                 MANPATH="/usr/man:/usr/share/man"
5164         fi
5165
5166         # look for the 'date' man-page (it's most likely to be installed!)
5167         MANPAGE_FORMAT=
5168         cf_preform=no
5169         cf_catonly=yes
5170         cf_example=date
5171
5172         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
5173         for cf_dir in $MANPATH; do
5174                 test -z "$cf_dir" && cf_dir=/usr/man
5175                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
5176                 do
5177                         cf_test=`echo $cf_name | sed -e 's/*//'`
5178                         if test "x$cf_test" = "x$cf_name" ; then
5179
5180                                 case "$cf_name" in
5181                                 (*.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
5182                                 (*.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
5183                                 (*.0)  MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
5184                                 (*)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
5185                                 esac
5186
5187                                 case "$cf_name" in
5188                                 ($cf_dir/man*)
5189                                         cf_catonly=no
5190                                         ;;
5191                                 ($cf_dir/cat*)
5192                                         cf_preform=yes
5193                                         ;;
5194                                 esac
5195                                 break
5196                         fi
5197
5198                         # if we found a match in either man* or cat*, stop looking
5199                         if test -n "$MANPAGE_FORMAT" ; then
5200                                 cf_found=no
5201                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
5202                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
5203                                 case "$cf_name" in
5204                                 ($cf_dir/cat*)
5205                                         cf_found=yes
5206                                         ;;
5207                                 esac
5208                                 test $cf_found=yes && break
5209                         fi
5210                 done
5211                 # only check the first directory in $MANPATH where we find manpages
5212                 if test -n "$MANPAGE_FORMAT" ; then
5213                         break
5214                 fi
5215         done
5216         # if we did not find the example, just assume it is normal
5217         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
5218         IFS="$ac_save_ifs"
5219         ;;
5220 (*)
5221         for cf_option in $MANPAGE_FORMAT; do
5222         case $cf_option in
5223         (gzip|compress|BSDI|normal|formatted|catonly)
5224                 ;;
5225         (*)
5226                 cf_unknown="$cf_unknown $cf_option"
5227                 ;;
5228         esac
5229         done
5230         ;;
5231 esac
5232
5233 AC_MSG_RESULT($MANPAGE_FORMAT)
5234 if test -n "$cf_unknown" ; then
5235         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
5236 fi
5237 ])dnl
5238 dnl ---------------------------------------------------------------------------
5239 dnl CF_MANPAGE_RENAMES version: 10 updated: 2015/08/05 20:44:28
5240 dnl ------------------
5241 dnl The Debian people have their own naming convention for manpages.  This
5242 dnl option lets us override the name of the file containing renaming, or
5243 dnl disable it altogether.
5244 AC_DEFUN([CF_MANPAGE_RENAMES],
5245 [
5246 AC_MSG_CHECKING(for manpage renaming)
5247
5248 AC_ARG_WITH(manpage-renames,
5249         [  --with-manpage-renames  specify manpage-renaming],
5250         [MANPAGE_RENAMES=$withval],
5251         [MANPAGE_RENAMES=yes])
5252
5253 case ".$MANPAGE_RENAMES" in
5254 (.no)
5255         ;;
5256 (.|.yes)
5257         # Debian 'man' program?
5258         if test -f /etc/debian_version ; then
5259                 MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
5260         else
5261                 MANPAGE_RENAMES=no
5262         fi
5263         ;;
5264 esac
5265
5266 if test "$MANPAGE_RENAMES" != no ; then
5267         if test -f $srcdir/man/$MANPAGE_RENAMES ; then
5268                 MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
5269         elif test ! -f $MANPAGE_RENAMES ; then
5270                 AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
5271         fi
5272
5273         test ! -d man && mkdir man
5274
5275         # Construct a sed-script to perform renaming within man-pages
5276         if test -n "$MANPAGE_RENAMES" ; then
5277                 test ! -d man && mkdir man
5278                 $SHELL $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
5279         fi
5280 fi
5281
5282 AC_MSG_RESULT($MANPAGE_RENAMES)
5283 AC_SUBST(MANPAGE_RENAMES)
5284 ])dnl
5285 dnl ---------------------------------------------------------------------------
5286 dnl CF_MANPAGE_SYMLINKS version: 6 updated: 2015/04/17 21:13:04
5287 dnl -------------------
5288 dnl Some people expect each tool to make all aliases for manpages in the
5289 dnl man-directory.  This accommodates the older, less-capable implementations
5290 dnl of 'man', and is optional.
5291 AC_DEFUN([CF_MANPAGE_SYMLINKS],
5292 [
5293 AC_MSG_CHECKING(if manpage aliases will be installed)
5294
5295 AC_ARG_WITH(manpage-aliases,
5296         [  --with-manpage-aliases  specify manpage-aliases using .so],
5297         [MANPAGE_ALIASES=$withval],
5298         [MANPAGE_ALIASES=yes])
5299
5300 AC_MSG_RESULT($MANPAGE_ALIASES)
5301
5302 case "x$LN_S" in
5303 (xln*)
5304         cf_use_symlinks=yes
5305         ;;
5306 (*)
5307         cf_use_symlinks=no
5308         ;;
5309 esac
5310
5311 MANPAGE_SYMLINKS=no
5312 if test "$MANPAGE_ALIASES" = yes ; then
5313 AC_MSG_CHECKING(if manpage symlinks should be used)
5314
5315 AC_ARG_WITH(manpage-symlinks,
5316         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
5317         [MANPAGE_SYMLINKS=$withval],
5318         [MANPAGE_SYMLINKS=$cf_use_symlinks])
5319
5320 if test "$$cf_use_symlinks" = no; then
5321 if test "$MANPAGE_SYMLINKS" = yes ; then
5322         AC_MSG_WARN(cannot make symlinks, will use .so files)
5323         MANPAGE_SYMLINKS=no
5324 fi
5325 fi
5326
5327 AC_MSG_RESULT($MANPAGE_SYMLINKS)
5328 fi
5329
5330 ])dnl
5331 dnl ---------------------------------------------------------------------------
5332 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
5333 dnl --------------
5334 dnl This option causes manpages to be run through tbl(1) to generate tables
5335 dnl correctly.
5336 AC_DEFUN([CF_MANPAGE_TBL],
5337 [
5338 AC_MSG_CHECKING(for manpage tbl)
5339
5340 AC_ARG_WITH(manpage-tbl,
5341         [  --with-manpage-tbl      specify manpage processing with tbl],
5342         [MANPAGE_TBL=$withval],
5343         [MANPAGE_TBL=no])
5344
5345 AC_MSG_RESULT($MANPAGE_TBL)
5346 ])dnl
5347 dnl ---------------------------------------------------------------------------
5348 dnl CF_MAN_PAGES version: 47 updated: 2017/08/12 07:58:51
5349 dnl ------------
5350 dnl Try to determine if the man-pages on the system are compressed, and if
5351 dnl so, what format is used.  Use this information to construct a script that
5352 dnl will install man-pages.
5353 AC_DEFUN([CF_MAN_PAGES],
5354 [
5355 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
5356 CF_MANPAGE_FORMAT
5357 CF_MANPAGE_RENAMES
5358 CF_MANPAGE_SYMLINKS
5359 CF_MANPAGE_TBL
5360
5361 if test "$prefix" = "NONE" ; then
5362         cf_prefix="$ac_default_prefix"
5363 else
5364         cf_prefix="$prefix"
5365 fi
5366
5367 case "$MANPAGE_FORMAT" in
5368 (*catonly*)
5369         cf_format=yes
5370         cf_inboth=no
5371         ;;
5372 (*formatted*)
5373         cf_format=yes
5374         cf_inboth=yes
5375         ;;
5376 (*)
5377         cf_format=no
5378         cf_inboth=no
5379         ;;
5380 esac
5381
5382 test ! -d man && mkdir man
5383
5384 cf_so_strip=
5385 cf_compress=
5386 case "$MANPAGE_FORMAT" in
5387 (*compress*)
5388         cf_so_strip="Z"
5389         cf_compress=compress
5390         ;;
5391 (*gzip*)
5392         cf_so_strip="gz"
5393         cf_compress=gzip
5394         ;;
5395 esac
5396
5397 cf_edit_man=./edit_man.sh
5398 cf_man_alias=`pwd`/man_alias.sed
5399
5400 cat >$cf_edit_man <<CF_EOF
5401 #! $SHELL
5402 # this script is generated by the configure-script CF_MAN_PAGES macro.
5403
5404 prefix="$cf_prefix"
5405 datarootdir="$datarootdir"
5406 datadir="$datadir"
5407
5408 NCURSES_MAJOR="$NCURSES_MAJOR"
5409 NCURSES_MINOR="$NCURSES_MINOR"
5410 NCURSES_PATCH="$NCURSES_PATCH"
5411
5412 NCURSES_OSPEED="$NCURSES_OSPEED"
5413 TERMINFO="$TERMINFO"
5414
5415 INSTALL="$INSTALL"
5416 INSTALL_DATA="$INSTALL_DATA"
5417
5418 transform="$program_transform_name"
5419
5420 TMP=\${TMPDIR:=/tmp}/man\$\$
5421 trap "rm -f \$TMP" 0 1 2 3 15
5422
5423 form=\[$]1
5424 shift || exit 1
5425
5426 verb=\[$]1
5427 shift || exit 1
5428
5429 mandir=\[$]1
5430 shift || exit 1
5431
5432 srcdir=\[$]1
5433 top_srcdir=\[$]srcdir/..
5434 shift || exit 1
5435
5436 if test "\$form" = normal ; then
5437         if test "$cf_format" = yes ; then
5438         if test "$cf_inboth" = no ; then
5439                 $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
5440                 exit $?
5441         fi
5442         fi
5443         cf_subdir=\$mandir/man
5444         cf_tables=$MANPAGE_TBL
5445 else
5446         cf_subdir=\$mandir/cat
5447         cf_tables=yes
5448 fi
5449
5450 # process the list of source-files
5451 for i in \[$]* ; do
5452 case \$i in
5453 (*.orig|*.rej) ;;
5454 (*.[[0-9]]*)
5455         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
5456         if test \$verb = installing ; then
5457         if test ! -d \$cf_subdir\${section} ; then
5458                 mkdir -p \$cf_subdir\$section
5459         fi
5460         fi
5461
5462         # replace variables in man page
5463         if test ! -f $cf_man_alias ; then
5464 cat >>$cf_man_alias <<-CF_EOF2
5465                 s,@DATADIR@,\$datadir,g
5466                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
5467                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
5468                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
5469                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
5470                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
5471                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
5472 CF_EOF
5473         ifelse($1,,,[
5474         for cf_name in $1
5475         do
5476                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
5477                 cf_name=`echo $cf_name|sed "$program_transform_name"`
5478 cat >>$cf_edit_man <<-CF_EOF
5479                 s,@$cf_NAME@,$cf_name,g
5480 CF_EOF
5481         done
5482         ])
5483 cat >>$cf_edit_man <<CF_EOF
5484 CF_EOF2
5485                 echo "...made $cf_man_alias"
5486         fi
5487
5488         aliases=
5489         cf_source=\`basename \$i\`
5490         inalias=\$cf_source
5491         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
5492         if test ! -f \$inalias ; then
5493                 echo .. skipped \$cf_source
5494                 continue
5495         fi
5496 CF_EOF
5497
5498 if test "$MANPAGE_ALIASES" != no ; then
5499 cat >>$cf_edit_man <<CF_EOF
5500         nCurses=ignore.3x
5501         test $with_curses_h = yes && nCurses=ncurses.3x
5502         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
5503 CF_EOF
5504 fi
5505
5506 if test "$MANPAGE_RENAMES" = no ; then
5507 cat >>$cf_edit_man <<CF_EOF
5508         # perform program transformations for section 1 man pages
5509         if test \$section = 1 ; then
5510                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
5511         else
5512                 cf_target=\$cf_subdir\${section}/\$cf_source
5513         fi
5514 CF_EOF
5515 else
5516 cat >>$cf_edit_man <<CF_EOF
5517         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
5518         if test -z "\$cf_target" ; then
5519                 echo '? missing rename for '\$cf_source
5520                 cf_target="\$cf_source"
5521         fi
5522         cf_target="\$cf_subdir\${section}/\${cf_target}"
5523
5524 CF_EOF
5525 fi
5526
5527 cat >>$cf_edit_man <<CF_EOF
5528         sed     -f $cf_man_alias \\
5529 CF_EOF
5530
5531 if test -f $MANPAGE_RENAMES ; then
5532 cat >>$cf_edit_man <<CF_EOF
5533                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
5534 CF_EOF
5535 else
5536 cat >>$cf_edit_man <<CF_EOF
5537                 < \$i >\$TMP
5538 CF_EOF
5539 fi
5540
5541 cat >>$cf_edit_man <<CF_EOF
5542 if test \$cf_tables = yes ; then
5543         tbl \$TMP >\$TMP.out
5544         mv \$TMP.out \$TMP
5545 fi
5546 CF_EOF
5547
5548 if test $with_overwrite != yes ; then
5549 cat >>$cf_edit_man <<CF_EOF
5550         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
5551         mv \$TMP.out \$TMP
5552 CF_EOF
5553 fi
5554
5555 if test $with_curses_h != yes ; then
5556 cat >>$cf_edit_man <<CF_EOF
5557         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
5558         mv \$TMP.out \$TMP
5559 CF_EOF
5560 fi
5561
5562 cat >>$cf_edit_man <<CF_EOF
5563         if test \$form = format ; then
5564                 nroff -man \$TMP >\$TMP.out
5565                 mv \$TMP.out \$TMP
5566         fi
5567 CF_EOF
5568
5569 if test -n "$cf_compress" ; then
5570 cat >>$cf_edit_man <<CF_EOF
5571         if test \$verb = installing ; then
5572         if ( $cf_compress -f \$TMP )
5573         then
5574                 mv \$TMP.$cf_so_strip \$TMP
5575         fi
5576         fi
5577         cf_target="\$cf_target.$cf_so_strip"
5578 CF_EOF
5579 fi
5580
5581 case "$MANPAGE_FORMAT" in
5582 (*BSDI*)
5583 cat >>$cf_edit_man <<CF_EOF
5584         if test \$form = format ; then
5585                 # BSDI installs only .0 suffixes in the cat directories
5586                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
5587         fi
5588 CF_EOF
5589   ;;
5590 esac
5591
5592 cat >>$cf_edit_man <<CF_EOF
5593         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
5594         if test \$verb = installing ; then
5595                 echo \$verb \$cf_target
5596                 \$INSTALL_DATA \$TMP \$cf_target
5597                 test -d \$cf_subdir\${section} &&
5598                 test -n "\$aliases" && (
5599                         cd \$cf_subdir\${section} && (
5600                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
5601                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
5602                                 cf_target=\`basename \$cf_target\`
5603                                 for cf_alias in \$aliases
5604                                 do
5605                                         if test \$section = 1 ; then
5606                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
5607                                         fi
5608
5609                                         if test "$MANPAGE_SYMLINKS" = yes ; then
5610                                                 if test -f \$cf_alias\${suffix} ; then
5611                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
5612                                                         then
5613                                                                 continue
5614                                                         fi
5615                                                 fi
5616                                                 echo .. \$verb alias \$cf_alias\${suffix}
5617 CF_EOF
5618 case "x$LN_S" in
5619 (*-f)
5620 cat >>$cf_edit_man <<CF_EOF
5621                                                 $LN_S \$cf_target \$cf_alias\${suffix}
5622 CF_EOF
5623         ;;
5624 (*)
5625 cat >>$cf_edit_man <<CF_EOF
5626                                                 rm -f \$cf_alias\${suffix}
5627                                                 $LN_S \$cf_target \$cf_alias\${suffix}
5628 CF_EOF
5629         ;;
5630 esac
5631 cat >>$cf_edit_man <<CF_EOF
5632                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
5633                                                 echo ".so \$cf_source" >\$TMP
5634 CF_EOF
5635 if test -n "$cf_compress" ; then
5636 cat >>$cf_edit_man <<CF_EOF
5637                                                 if test -n "$cf_so_strip" ; then
5638                                                         $cf_compress -f \$TMP
5639                                                         mv \$TMP.$cf_so_strip \$TMP
5640                                                 fi
5641 CF_EOF
5642 fi
5643 cat >>$cf_edit_man <<CF_EOF
5644                                                 echo .. \$verb alias \$cf_alias\${suffix}
5645                                                 rm -f \$cf_alias\${suffix}
5646                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
5647                                         fi
5648                                 done
5649                         )
5650                 )
5651         elif test \$verb = removing ; then
5652                 test -f \$cf_target && (
5653                         echo \$verb \$cf_target
5654                         rm -f \$cf_target
5655                 )
5656                 test -d \$cf_subdir\${section} &&
5657                 test -n "\$aliases" && (
5658                         cd \$cf_subdir\${section} && (
5659                                 for cf_alias in \$aliases
5660                                 do
5661                                         if test \$section = 1 ; then
5662                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
5663                                         fi
5664
5665                                         echo .. \$verb alias \$cf_alias\${suffix}
5666                                         rm -f \$cf_alias\${suffix}
5667                                 done
5668                         )
5669                 )
5670         else
5671 #               echo ".hy 0"
5672                 cat \$TMP
5673         fi
5674         ;;
5675 esac
5676 done
5677
5678 if test $cf_inboth = yes ; then
5679 if test \$form != format ; then
5680         $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
5681 fi
5682 fi
5683
5684 exit 0
5685 CF_EOF
5686 chmod 755 $cf_edit_man
5687
5688 ])dnl
5689 dnl ---------------------------------------------------------------------------
5690 dnl CF_MAP_LIB_BASENAME version: 1 updated: 2020/03/07 20:05:14
5691 dnl -------------------
5692 dnl Convert a default-libname to the actual one used via CF_WITH_LIB_BASENAME.
5693 dnl
5694 dnl $1 = variable to set
5695 dnl $2 = default-libname
5696 AC_DEFUN([CF_MAP_LIB_BASENAME],[
5697 CF_UPPER(cf_map_lib_basename,$2)
5698 eval $1=\$${cf_map_lib_basename}_NAME
5699 ])dnl
5700 dnl ---------------------------------------------------------------------------
5701 dnl CF_MATH_LIB version: 9 updated: 2017/01/21 11:06:25
5702 dnl -----------
5703 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
5704 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
5705 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
5706 AC_DEFUN([CF_MATH_LIB],
5707 [
5708 AC_CACHE_CHECK(if -lm needed for math functions,
5709         cf_cv_need_libm,[
5710         AC_TRY_LINK([
5711         #include <stdio.h>
5712         #include <stdlib.h>
5713         #include <math.h>
5714         ],
5715         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
5716         [cf_cv_need_libm=no],
5717         [cf_cv_need_libm=yes])])
5718 if test "$cf_cv_need_libm" = yes
5719 then
5720 ifelse($1,,[
5721         CF_ADD_LIB(m)
5722 ],[$1=-lm])
5723 fi
5724 ])
5725 dnl ---------------------------------------------------------------------------
5726 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
5727 dnl ----------------------
5728 dnl Check if the file-system supports mixed-case filenames.  If we're able to
5729 dnl create a lowercase name and see it as uppercase, it doesn't support that.
5730 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
5731 [
5732 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
5733 if test "$cross_compiling" = yes ; then
5734         case $target_alias in
5735         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
5736                 cf_cv_mixedcase=no
5737                 ;;
5738         (*)
5739                 cf_cv_mixedcase=yes
5740                 ;;
5741         esac
5742 else
5743         rm -f conftest CONFTEST
5744         echo test >conftest
5745         if test -f CONFTEST ; then
5746                 cf_cv_mixedcase=no
5747         else
5748                 cf_cv_mixedcase=yes
5749         fi
5750         rm -f conftest CONFTEST
5751 fi
5752 ])
5753 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
5754 ])dnl
5755 dnl ---------------------------------------------------------------------------
5756 dnl CF_MKSTEMP version: 10 updated: 2017/01/21 11:12:16
5757 dnl ----------
5758 dnl Check for a working mkstemp.  This creates two files, checks that they are
5759 dnl successfully created and distinct (AmigaOS apparently fails on the last).
5760 AC_DEFUN([CF_MKSTEMP],[
5761 AC_CHECK_HEADERS( \
5762 unistd.h \
5763 )
5764 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
5765 rm -rf conftest*
5766 AC_TRY_RUN([
5767 #include <sys/types.h>
5768 #ifdef HAVE_UNISTD_H
5769 #include <unistd.h>
5770 #endif
5771 #include <stdlib.h>
5772 #include <stdio.h>
5773 #include <string.h>
5774 #include <sys/stat.h>
5775 int main(void)
5776 {
5777         char *tmpl = "conftestXXXXXX";
5778         char name[2][80];
5779         int n;
5780         int result = 0;
5781         int fd;
5782         struct stat sb;
5783
5784         umask(077);
5785         for (n = 0; n < 2; ++n) {
5786                 strcpy(name[n], tmpl);
5787                 if ((fd = mkstemp(name[n])) >= 0) {
5788                         if (!strcmp(name[n], tmpl)
5789                          || stat(name[n], &sb) != 0
5790                          || (sb.st_mode & S_IFMT) != S_IFREG
5791                          || (sb.st_mode & 077) != 0) {
5792                                 result = 1;
5793                         }
5794                         close(fd);
5795                 }
5796         }
5797         if (result == 0
5798          && !strcmp(name[0], name[1]))
5799                 result = 1;
5800         ${cf_cv_main_return:-return}(result);
5801 }
5802 ],[cf_cv_func_mkstemp=yes
5803 ],[cf_cv_func_mkstemp=no
5804 ],[cf_cv_func_mkstemp=maybe])
5805 ])
5806 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
5807         AC_CHECK_FUNC(mkstemp)
5808 fi
5809 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
5810         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
5811 fi
5812 ])dnl
5813 dnl ---------------------------------------------------------------------------
5814 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
5815 dnl ----------
5816 dnl Write a debug message to config.log, along with the line number in the
5817 dnl configure script.
5818 AC_DEFUN([CF_MSG_LOG],[
5819 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
5820 ])dnl
5821 dnl ---------------------------------------------------------------------------
5822 dnl CF_NCURSES_ABI_6 version: 3 updated: 2015/06/06 16:10:11
5823 dnl ----------------
5824 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
5825 dnl warn about this.
5826 AC_DEFUN([CF_NCURSES_ABI_6],[
5827 if test "${with_abi_version+set}" != set; then
5828         case $cf_cv_rel_version in
5829         (5.*)
5830                 cf_cv_rel_version=6.0
5831                 cf_cv_abi_version=6
5832                 AC_MSG_WARN(overriding ABI version to $cf_cv_abi_version)
5833                 ;;
5834         esac
5835 fi
5836 ])dnl
5837 dnl ---------------------------------------------------------------------------
5838 dnl CF_NCURSES_WITH_ABI_VERSION version: 2 updated: 2015/12/19 17:51:52
5839 dnl ---------------------------
5840 dnl Allow ncurses's ABI to be overridden.  Generally this happens when a
5841 dnl packager has incremented the ABI past that used in the original package,
5842 dnl and wishes to keep doing this.
5843 dnl
5844 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
5845 dnl symbol.
5846 AC_DEFUN([CF_NCURSES_WITH_ABI_VERSION],[
5847 CF_WITH_ABI_VERSION($1)
5848 if test "x$cf_cv_abi_version" != "x$with_abi_version"
5849 then
5850         case $cf_cv_rel_version in
5851         (5.*)
5852                 cf_cv_rel_version=$with_abi_version.0
5853                 ;;
5854         esac
5855 fi
5856 ])dnl
5857 dnl ---------------------------------------------------------------------------
5858 dnl CF_NO_LEAKS_OPTION version: 6 updated: 2015/04/12 15:39:00
5859 dnl ------------------
5860 dnl see CF_WITH_NO_LEAKS
5861 AC_DEFUN([CF_NO_LEAKS_OPTION],[
5862 AC_MSG_CHECKING(if you want to use $1 for testing)
5863 AC_ARG_WITH($1,
5864         [$2],
5865         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
5866          $4
5867 ])
5868         : ${with_cflags:=-g}
5869         : ${with_no_leaks:=yes}
5870          with_$1=yes],
5871         [with_$1=])
5872 AC_MSG_RESULT(${with_$1:-no})
5873
5874 case .$with_cflags in
5875 (.*-g*)
5876         case .$CFLAGS in
5877         (.*-g*)
5878                 ;;
5879         (*)
5880                 CF_ADD_CFLAGS([-g])
5881                 ;;
5882         esac
5883         ;;
5884 esac
5885 ])dnl
5886 dnl ---------------------------------------------------------------------------
5887 dnl CF_NUMBER_SYNTAX version: 2 updated: 2015/04/17 21:13:04
5888 dnl ----------------
5889 dnl Check if the given variable is a number.  If not, report an error.
5890 dnl $1 is the variable
5891 dnl $2 is the message
5892 AC_DEFUN([CF_NUMBER_SYNTAX],[
5893 if test -n "$1" ; then
5894   case $1 in
5895   ([[0-9]]*)
5896         ;;
5897   (*)
5898         AC_MSG_ERROR($2 is not a number: $1)
5899         ;;
5900   esac
5901 else
5902   AC_MSG_ERROR($2 value is empty)
5903 fi
5904 ])dnl
5905 dnl ---------------------------------------------------------------------------
5906 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
5907 dnl -------------
5908 dnl Compute the object-directory name from the given model name
5909 AC_DEFUN([CF_OBJ_SUBDIR],
5910 [
5911         case $1 in
5912         (libtool) $2='obj_lo'  ;;
5913         (normal)  $2='objects' ;;
5914         (debug)   $2='obj_g' ;;
5915         (profile) $2='obj_p' ;;
5916         (shared)
5917                 case $cf_cv_system_name in
5918                 (cygwin|msys)
5919                         $2='objects' ;;
5920                 (*)
5921                         $2='obj_s' ;;
5922                 esac
5923         esac
5924 ])dnl
5925 dnl ---------------------------------------------------------------------------
5926 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
5927 dnl ----------
5928 dnl Provide a value for the $PATH and similar separator (or amend the value
5929 dnl as provided in autoconf 2.5x).
5930 AC_DEFUN([CF_PATHSEP],
5931 [
5932         AC_MSG_CHECKING(for PATH separator)
5933         case $cf_cv_system_name in
5934         (os2*)  PATH_SEPARATOR=';'  ;;
5935         (*)     ${PATH_SEPARATOR:=':'}  ;;
5936         esac
5937 ifelse([$1],,,[$1=$PATH_SEPARATOR])
5938         AC_SUBST(PATH_SEPARATOR)
5939         AC_MSG_RESULT($PATH_SEPARATOR)
5940 ])dnl
5941 dnl ---------------------------------------------------------------------------
5942 dnl CF_PATH_PROG version: 10 updated: 2019/06/30 19:44:43
5943 dnl ------------
5944 dnl Check for a given program, defining corresponding symbol.
5945 dnl     $1 = environment variable, which is suffixed by "_PATH" in the #define.
5946 dnl     $2 = program name to find.
5947 dnl     $3 = optional list of additional program names to test.
5948 dnl $4 = $PATH
5949 dnl
5950 dnl If there is more than one token in the result, #define the remaining tokens
5951 dnl to $1_ARGS.  We need this for 'install' in particular.
5952 dnl
5953 dnl FIXME: we should allow this to be overridden by environment variables
5954 dnl
5955 AC_DEFUN([CF_PATH_PROG],[
5956 AC_REQUIRE([CF_PATHSEP])
5957 test -z "[$]$1" && $1=$2
5958 AC_PATH_PROGS($1,[$]$1 $2 ifelse($3,,,$3),[$]$1, ifelse($4,,,$4))
5959
5960 cf_path_prog=""
5961 cf_path_args=""
5962 IFS="${IFS:-    }"; cf_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR"
5963 for cf_temp in $ac_cv_path_$1
5964 do
5965         if test -z "$cf_path_prog" ; then
5966                 if test "$with_full_paths" = yes ; then
5967                         CF_PATH_SYNTAX(cf_temp,break)
5968                         cf_path_prog="$cf_temp"
5969                 else
5970                         cf_path_prog="`basename $cf_temp`"
5971                 fi
5972         elif test -z "$cf_path_args" ; then
5973                 cf_path_args="$cf_temp"
5974         else
5975                 cf_path_args="$cf_path_args $cf_temp"
5976         fi
5977 done
5978 IFS="$cf_save_ifs"
5979
5980 if test -n "$cf_path_prog" ; then
5981         CF_MSG_LOG(defining path for ${cf_path_prog})
5982         AC_DEFINE_UNQUOTED($1_PATH,"$cf_path_prog",Define to pathname $1)
5983         test -n "$cf_path_args" && AC_DEFINE_UNQUOTED($1_ARGS,"$cf_path_args",Define to provide args for $1)
5984 fi
5985 ])dnl
5986 dnl ---------------------------------------------------------------------------
5987 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
5988 dnl --------------
5989 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
5990 dnl begins with one of the prefix/exec_prefix variables, and then again if the
5991 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
5992 dnl delayed evaluation of those symbols.
5993 AC_DEFUN([CF_PATH_SYNTAX],[
5994 if test "x$prefix" != xNONE; then
5995         cf_path_syntax="$prefix"
5996 else
5997         cf_path_syntax="$ac_default_prefix"
5998 fi
5999
6000 case ".[$]$1" in
6001 (.\[$]\(*\)*|.\'*\'*)
6002         ;;
6003 (..|./*|.\\*)
6004         ;;
6005 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
6006         ;;
6007 (.\[$]{*prefix}*|.\[$]{*dir}*)
6008         eval $1="[$]$1"
6009         case ".[$]$1" in
6010         (.NONE/*)
6011                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
6012                 ;;
6013         esac
6014         ;;
6015 (.no|.NONE/*)
6016         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
6017         ;;
6018 (*)
6019         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
6020         ;;
6021 esac
6022 ])dnl
6023 dnl ---------------------------------------------------------------------------
6024 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
6025 dnl -------------
6026 dnl Check for the package-config program, unless disabled by command-line.
6027 AC_DEFUN([CF_PKG_CONFIG],
6028 [
6029 AC_MSG_CHECKING(if you want to use pkg-config)
6030 AC_ARG_WITH(pkg-config,
6031         [  --with-pkg-config{=path} enable/disable use of pkg-config],
6032         [cf_pkg_config=$withval],
6033         [cf_pkg_config=yes])
6034 AC_MSG_RESULT($cf_pkg_config)
6035
6036 case $cf_pkg_config in
6037 (no)
6038         PKG_CONFIG=none
6039         ;;
6040 (yes)
6041         CF_ACVERSION_CHECK(2.52,
6042                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
6043                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
6044         ;;
6045 (*)
6046         PKG_CONFIG=$withval
6047         ;;
6048 esac
6049
6050 test -z "$PKG_CONFIG" && PKG_CONFIG=none
6051 if test "$PKG_CONFIG" != none ; then
6052         CF_PATH_SYNTAX(PKG_CONFIG)
6053 elif test "x$cf_pkg_config" != xno ; then
6054         AC_MSG_WARN(pkg-config is not installed)
6055 fi
6056
6057 AC_SUBST(PKG_CONFIG)
6058 ])dnl
6059 dnl ---------------------------------------------------------------------------
6060 dnl CF_POSIX_C_SOURCE version: 11 updated: 2018/12/31 20:46:17
6061 dnl -----------------
6062 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
6063 dnl
6064 dnl     POSIX.1-1990                            _POSIX_SOURCE
6065 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
6066 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
6067 dnl             Bindings Option
6068 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
6069 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
6070 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
6071 dnl
6072 dnl Parameters:
6073 dnl     $1 is the nominal value for _POSIX_C_SOURCE
6074 AC_DEFUN([CF_POSIX_C_SOURCE],
6075 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
6076
6077 if test "$cf_cv_posix_visible" = no; then
6078
6079 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
6080
6081 cf_save_CFLAGS="$CFLAGS"
6082 cf_save_CPPFLAGS="$CPPFLAGS"
6083
6084 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
6085 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
6086
6087 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
6088         CF_MSG_LOG(if the symbol is already defined go no further)
6089         AC_TRY_COMPILE([#include <sys/types.h>],[
6090 #ifndef _POSIX_C_SOURCE
6091 make an error
6092 #endif],
6093         [cf_cv_posix_c_source=no],
6094         [cf_want_posix_source=no
6095          case .$cf_POSIX_C_SOURCE in
6096          (.[[12]]??*)
6097                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
6098                 ;;
6099          (.2)
6100                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
6101                 cf_want_posix_source=yes
6102                 ;;
6103          (.*)
6104                 cf_want_posix_source=yes
6105                 ;;
6106          esac
6107          if test "$cf_want_posix_source" = yes ; then
6108                 AC_TRY_COMPILE([#include <sys/types.h>],[
6109 #ifdef _POSIX_SOURCE
6110 make an error
6111 #endif],[],
6112                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
6113          fi
6114          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
6115          CFLAGS="$cf_trim_CFLAGS"
6116          CPPFLAGS="$cf_trim_CPPFLAGS"
6117          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
6118          CF_MSG_LOG(if the second compile does not leave our definition intact error)
6119          AC_TRY_COMPILE([#include <sys/types.h>],[
6120 #ifndef _POSIX_C_SOURCE
6121 make an error
6122 #endif],,
6123          [cf_cv_posix_c_source=no])
6124          CFLAGS="$cf_save_CFLAGS"
6125          CPPFLAGS="$cf_save_CPPFLAGS"
6126         ])
6127 ])
6128
6129 if test "$cf_cv_posix_c_source" != no ; then
6130         CFLAGS="$cf_trim_CFLAGS"
6131         CPPFLAGS="$cf_trim_CPPFLAGS"
6132         CF_ADD_CFLAGS($cf_cv_posix_c_source)
6133 fi
6134
6135 fi # cf_cv_posix_visible
6136
6137 ])dnl
6138 dnl ---------------------------------------------------------------------------
6139 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
6140 dnl ----------------
6141 dnl POSIX documents test-macros which an application may set before any system
6142 dnl headers are included to make features available.
6143 dnl
6144 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
6145 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
6146 dnl recent features visible in the system header files unless the application
6147 dnl overrides the corresponding test-macros.  Doing that introduces portability
6148 dnl problems.
6149 dnl
6150 dnl This macro makes a special check for the symbols used for this, to avoid a
6151 dnl conflicting definition.
6152 AC_DEFUN([CF_POSIX_VISIBLE],
6153 [
6154 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
6155 AC_TRY_COMPILE([#include <stdio.h>],[
6156 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
6157         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
6158         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
6159         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
6160 #error conflicting symbols found
6161 #endif
6162 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
6163 ])
6164 ])dnl
6165 dnl ---------------------------------------------------------------------------
6166 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
6167 dnl ------------
6168 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
6169 dnl
6170 dnl $1 = symbol to test
6171 dnl $2 = value (if any) to use for a predefinition
6172 AC_DEFUN([CF_PREDEFINE],
6173 [
6174 AC_MSG_CHECKING(if we must define $1)
6175 AC_TRY_COMPILE([#include <sys/types.h>
6176 ],[
6177 #ifndef $1
6178 make an error
6179 #endif],[cf_result=no],[cf_result=yes])
6180 AC_MSG_RESULT($cf_result)
6181
6182 if test "$cf_result" = yes ; then
6183         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
6184 elif test "x$2" != "x" ; then
6185         AC_MSG_CHECKING(checking for compatible value versus $2)
6186         AC_TRY_COMPILE([#include <sys/types.h>
6187 ],[
6188 #if $1-$2 < 0
6189 make an error
6190 #endif],[cf_result=yes],[cf_result=no])
6191         AC_MSG_RESULT($cf_result)
6192         if test "$cf_result" = no ; then
6193                 # perhaps we can override it - try...
6194                 CPPFLAGS="$CPPFLAGS -D$1=$2"
6195         fi
6196 fi
6197 ])dnl
6198 dnl ---------------------------------------------------------------------------
6199 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
6200 dnl ------------
6201 dnl Append definitions and rules for the given programs to the subdirectory
6202 dnl Makefiles, and the recursion rule for the top-level Makefile.
6203 dnl
6204 dnl parameters
6205 dnl     $1 = script to run
6206 dnl     $2 = list of subdirectories
6207 dnl
6208 dnl variables
6209 dnl     $AWK
6210 AC_DEFUN([CF_PRG_RULES],
6211 [
6212 for cf_dir in $2
6213 do
6214         if test ! -d $srcdir/$cf_dir; then
6215                 continue
6216         elif test -f $srcdir/$cf_dir/programs; then
6217                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
6218         fi
6219 done
6220
6221 ])dnl
6222 dnl ---------------------------------------------------------------------------
6223 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
6224 dnl ----------
6225 dnl Check for archiver "ar".
6226 AC_DEFUN([CF_PROG_AR],[
6227 AC_CHECK_TOOL(AR, ar, ar)
6228 ])
6229 dnl ---------------------------------------------------------------------------
6230 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
6231 dnl -----------
6232 dnl Check for awk, ensure that the check found something.
6233 AC_DEFUN([CF_PROG_AWK],
6234 [
6235 AC_PROG_AWK
6236 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
6237 ])dnl
6238 dnl ---------------------------------------------------------------------------
6239 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
6240 dnl ----------
6241 dnl standard check for CC, plus followup sanity checks
6242 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
6243 AC_DEFUN([CF_PROG_CC],[
6244 CF_ACVERSION_CHECK(2.53,
6245         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
6246          AC_REQUIRE([AC_PROG_CC])],
6247         [])
6248 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
6249 CF_GCC_VERSION
6250 CF_ACVERSION_CHECK(2.52,
6251         [AC_PROG_CC_STDC],
6252         [CF_ANSI_CC_REQD])
6253 CF_CC_ENV_FLAGS
6254 ])dnl
6255 dnl ---------------------------------------------------------------------------
6256 dnl CF_PROG_CC_C_O version: 5 updated: 2017/01/21 11:06:25
6257 dnl --------------
6258 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
6259 dnl the output file can be renamed, and allows for a shell variable that can
6260 dnl be used later.  The parameter is either CC or CXX.  The result is the
6261 dnl cache variable:
6262 dnl     $cf_cv_prog_CC_c_o
6263 dnl     $cf_cv_prog_CXX_c_o
6264 dnl
6265 dnl $1 = compiler
6266 dnl $2 = compiler options, if any
6267 AC_DEFUN([CF_PROG_CC_C_O],
6268 [AC_REQUIRE([AC_PROG_CC])dnl
6269 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
6270 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
6271 [
6272 cat > conftest.$ac_ext <<CF_EOF
6273 int main(void)
6274 {
6275         ${cf_cv_main_return:-return}(0);
6276 }
6277 CF_EOF
6278 # We do the test twice because some compilers refuse to overwrite an
6279 # existing .o file with -o, though they will create one.
6280 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
6281 if AC_TRY_EVAL(ac_try) &&
6282   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
6283 then
6284   eval cf_cv_prog_$1_c_o=yes
6285 else
6286   eval cf_cv_prog_$1_c_o=no
6287 fi
6288 rm -rf conftest*
6289 ])dnl
6290 if test $cf_cv_prog_$1_c_o = yes; then
6291   AC_MSG_RESULT([yes])
6292 else
6293   AC_MSG_RESULT([no])
6294 fi
6295 ])dnl
6296 dnl ---------------------------------------------------------------------------
6297 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
6298 dnl -------------
6299 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
6300 dnl This macro adds a check to ensure the script found something.
6301 AC_DEFUN([CF_PROG_EGREP],
6302 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
6303         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
6304                 then ac_cv_prog_egrep='grep -E'
6305                 else ac_cv_prog_egrep='egrep'
6306         fi])
6307         EGREP=$ac_cv_prog_egrep
6308         AC_SUBST([EGREP])
6309         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
6310 ])dnl
6311 dnl ---------------------------------------------------------------------------
6312 dnl CF_PROG_GNAT version: 10 updated: 2019/12/31 08:53:54
6313 dnl ------------
6314 dnl Check for gnat/gnatmake/etc, ensure that the toolset is complete.
6315 AC_DEFUN([CF_PROG_GNAT],[
6316 for cf_prog_gnat in gnat gnatmake gprconfig gprbuild
6317 do
6318         CF_UPPER(cf_upper_prog_gnat,${cf_prog_gnat})
6319
6320         unset ac_cv_path_cf_TEMP_gnat
6321         unset cf_TEMP_gnat
6322         AC_PATH_PROG(cf_TEMP_gnat,$cf_prog_gnat,no)
6323         eval cf_cv_PATH_$cf_upper_prog_gnat=[$]ac_cv_path_cf_TEMP_gnat
6324
6325         if test "x$cf_TEMP_gnat" != xno; then
6326                 unset cf_cv_gnat_version
6327                 unset cf_TEMP_gnat
6328                 CF_GNAT_VERSION(cf_TEMP_gnat,$cf_prog_gnat)
6329         fi
6330         eval cf_cv_VERSION_$cf_upper_prog_gnat=[$]cf_TEMP_gnat
6331
6332         unset cf_TEMP_gnat
6333         unset cf_cv_gnat_version
6334         unset ac_cv_path_cf_TEMP_gnat
6335 done
6336
6337 if test "x$cf_cv_VERSION_GNATMAKE" = "xno"; then
6338         cf_ada_make=
6339         cf_cv_prog_gnat_correct=no
6340 else
6341         cf_ada_make=gnatmake
6342         if test "x$cf_cv_VERSION_GPRCONFIG" = "xno"; then
6343                 # gprconfig is newer than gnatmake; we can continue...
6344                 cf_ada_config="##"
6345         else
6346                 rm -rf conftest* *~conftest*
6347                 if mkdir conftest.src
6348                 then
6349                         cf_ada_config=""
6350                         cd conftest.src
6351                         for cf_gprconfig in Ada C
6352                         do
6353                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
6354                                 if test $cf_gprconfig = C
6355                                 then
6356                                         for cf_gprconfig_param in \
6357                                                 $cf_gprconfig,,,,GNATGCC \
6358                                                 $cf_gprconfig,,,,GCC \
6359                                                 $cf_gprconfig
6360                                         do
6361                                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6362                                                 test -n "$cf_gprconfig_value" && break
6363                                         done
6364                                 else
6365                                         cf_gprconfig_param=$cf_gprconfig
6366                                         cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6367                                 fi
6368                                 if test -n "$cf_gprconfig_value"
6369                                 then
6370                                         eval cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value
6371                                         AC_MSG_RESULT($cf_gprconfig_value)
6372                                 else
6373                                         AC_MSG_RESULT(missing)
6374                                         cf_ada_config="#"
6375                                         break
6376                                 fi
6377                         done
6378                         cd ..
6379                         rm -rf conftest* *~conftest*
6380                 fi
6381         fi
6382         if test "x$cf_ada_config" != "x#"
6383         then
6384                 CF_GNAT_VERSION
6385                 CF_CHECK_GNAT_VERSION
6386                 AC_CHECK_PROG(M4_exists, m4, yes, no)
6387                 if test "$ac_cv_prog_M4_exists" = no; then
6388                         cf_cv_prog_gnat_correct=no
6389                         AC_MSG_WARN(Ada95 binding required program m4 not found. Ada95 binding disabled)
6390                 fi
6391                 if test "$cf_cv_prog_gnat_correct" = yes; then
6392                         AC_MSG_CHECKING(if GNAT works)
6393                         CF_GNAT_TRY_RUN([procedure conftest;],
6394 [with Text_IO;
6395 with GNAT.OS_Lib;
6396 procedure conftest is
6397 begin
6398    Text_IO.Put ("Hello World");
6399    Text_IO.New_Line;
6400    GNAT.OS_Lib.OS_Exit (0);
6401 end conftest;],
6402 [cf_cv_prog_gnat_correct=yes],
6403 [cf_cv_prog_gnat_correct=no])
6404                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
6405                 fi
6406         else
6407                 cf_cv_prog_gnat_correct=no
6408         fi
6409 fi
6410
6411 AC_SUBST(cf_ada_make)
6412 AC_SUBST(cf_ada_config)
6413 AC_SUBST(cf_ada_config_Ada)
6414 AC_SUBST(cf_ada_config_C)
6415 ])dnl
6416 dnl ---------------------------------------------------------------------------
6417 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
6418 dnl ---------------
6419 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
6420 dnl misc/tabset install won't work properly.  Usually this happens only when
6421 dnl using the fallback mkinstalldirs script
6422 AC_DEFUN([CF_PROG_INSTALL],
6423 [AC_PROG_INSTALL
6424 case $INSTALL in
6425 (/*)
6426         ;;
6427 (*)
6428         CF_DIRNAME(cf_dir,$INSTALL)
6429         test -z "$cf_dir" && cf_dir=.
6430         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
6431         ;;
6432 esac
6433 ])dnl
6434 dnl ---------------------------------------------------------------------------
6435 dnl CF_PROG_LDCONFIG version: 5 updated: 2015/04/18 08:56:57
6436 dnl ----------------
6437 dnl Check for ldconfig, needed to fixup shared libraries that would be built
6438 dnl and then used in the install.
6439 AC_DEFUN([CF_PROG_LDCONFIG],[
6440 if test "$cross_compiling" = yes ; then
6441         LDCONFIG=:
6442 else
6443         case "$cf_cv_system_name" in
6444         (dragonfly*|mirbsd*|freebsd*)
6445                 test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
6446                 ;;
6447         (*) LDPATH=$PATH:/sbin:/usr/sbin
6448                 AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
6449                 ;;
6450         esac
6451 fi
6452 AC_SUBST(LDCONFIG)
6453 ])dnl
6454 dnl ---------------------------------------------------------------------------
6455 dnl CF_PROG_LINT version: 4 updated: 2019/11/20 18:55:37
6456 dnl ------------
6457 AC_DEFUN([CF_PROG_LINT],
6458 [
6459 AC_CHECK_PROGS(LINT, lint cppcheck splint)
6460 case "x$LINT" in
6461 (xcppcheck|x*/cppcheck)
6462         test -z "$LINT_OPTS" && LINT_OPTS="--enable=all"
6463         ;;
6464 esac
6465 AC_SUBST(LINT_OPTS)
6466 ])dnl
6467 dnl ---------------------------------------------------------------------------
6468 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
6469 dnl ------------
6470 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
6471 dnl option if it is supported.
6472 AC_DEFUN([CF_PROG_LN_S],[
6473 AC_PROG_LN_S
6474 AC_MSG_CHECKING(if $LN_S -f options work)
6475
6476 rm -f conf$$.src conf$$dst
6477 echo >conf$$.dst
6478 echo first >conf$$.src
6479 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
6480         cf_prog_ln_sf=yes
6481 else
6482         cf_prog_ln_sf=no
6483 fi
6484 rm -f conf$$.dst conf$$src
6485 AC_MSG_RESULT($cf_prog_ln_sf)
6486
6487 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
6488 ])dnl
6489 dnl ---------------------------------------------------------------------------
6490 dnl CF_REGEX version: 16 updated: 2020/09/26 19:56:36
6491 dnl --------
6492 dnl Attempt to determine if we've got one of the flavors of regular-expression
6493 dnl code that we can support.
6494 AC_DEFUN([CF_REGEX],
6495 [
6496
6497 cf_regex_func=no
6498 cf_regex_libs=
6499 case $host_os in
6500 (mingw*)
6501         # -lsystre -ltre -lintl -liconv
6502         AC_CHECK_LIB(systre,regcomp,[
6503                 AC_CHECK_LIB(iconv,libiconv_open,[CF_ADD_LIB(iconv)])
6504                 AC_CHECK_LIB(intl,libintl_gettext,[CF_ADD_LIB(intl)])
6505                 AC_CHECK_LIB(tre,tre_regcomp,[CF_ADD_LIB(tre)])
6506                 CF_ADD_LIB(systre)
6507                 cf_regex_func=regcomp
6508         ],[
6509                 AC_CHECK_LIB(gnurx,regcomp,[
6510                         CF_ADD_LIB(gnurx)
6511                         cf_regex_func=regcomp])
6512         ])
6513         ;;
6514 (*)
6515         cf_regex_libs="regex re"
6516         AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
6517                 for cf_regex_lib in $cf_regex_libs
6518                 do
6519                         AC_CHECK_LIB($cf_regex_lib,regcomp,[
6520                                         CF_ADD_LIB($cf_regex_lib)
6521                                         cf_regex_func=regcomp
6522                                         break])
6523                 done
6524         ])
6525         ;;
6526 esac
6527
6528 if test "$cf_regex_func" = no ; then
6529         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
6530                 AC_CHECK_LIB(gen,compile,[
6531                                 CF_ADD_LIB(gen)
6532                                 cf_regex_func=compile])])
6533 fi
6534
6535 if test "$cf_regex_func" = no ; then
6536         AC_MSG_WARN(cannot find regular expression library)
6537 fi
6538
6539 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
6540
6541 cf_cv_regex_hdrs=no
6542 case $cf_regex_func in
6543 (compile)
6544         for cf_regex_hdr in regexp.h regexpr.h
6545         do
6546                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
6547                         char *p = compile("", "", "", 0);
6548                         int x = step("", "");
6549                         (void)p;
6550                         (void)x;
6551                 ],[
6552                         cf_cv_regex_hdrs=$cf_regex_hdr
6553                         break
6554                 ])
6555         done
6556         ;;
6557 (*)
6558         for cf_regex_hdr in regex.h
6559         do
6560                 AC_TRY_LINK([#include <sys/types.h>
6561 #include <$cf_regex_hdr>],[
6562                         regex_t *p = 0;
6563                         int x = regcomp(p, "", 0);
6564                         int y = regexec(p, "", 0, 0, 0);
6565                         (void)x;
6566                         (void)y;
6567                         regfree(p);
6568                 ],[
6569                         cf_cv_regex_hdrs=$cf_regex_hdr
6570                         break
6571                 ])
6572         done
6573         ;;
6574 esac
6575
6576 ])
6577
6578 case $cf_cv_regex_hdrs in
6579         (no)            AC_MSG_WARN(no regular expression header found) ;;
6580         (regex.h)       AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;;
6581         (regexp.h)      AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;;
6582         (regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
6583 esac
6584 ])dnl
6585 dnl ---------------------------------------------------------------------------
6586 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
6587 dnl ----------------
6588 dnl Remove all -U and -D options that refer to the given symbol from a list
6589 dnl of C compiler options.  This works around the problem that not all
6590 dnl compilers process -U and -D options from left-to-right, so a -U option
6591 dnl cannot be used to cancel the effect of a preceding -D option.
6592 dnl
6593 dnl $1 = target (which could be the same as the source variable)
6594 dnl $2 = source (including '$')
6595 dnl $3 = symbol to remove
6596 define([CF_REMOVE_DEFINE],
6597 [
6598 $1=`echo "$2" | \
6599         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
6600                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
6601 ])dnl
6602 dnl ---------------------------------------------------------------------------
6603 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
6604 dnl -------------
6605 dnl Remove the given library from the symbol
6606 dnl
6607 dnl $1 = target (which could be the same as the source variable)
6608 dnl $2 = source (including '$')
6609 dnl $3 = library to remove
6610 define([CF_REMOVE_LIB],
6611 [
6612 # remove $3 library from $2
6613 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
6614 ])dnl
6615 dnl ---------------------------------------------------------------------------
6616 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
6617 dnl ---------------------
6618 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
6619 dnl $1 = name of current macro
6620 define([CF_RESTORE_XTRA_FLAGS],
6621 [
6622 LIBS="$cf_save_LIBS_$1"
6623 CFLAGS="$cf_save_CFLAGS_$1"
6624 CPPFLAGS="$cf_save_CPPFLAGS_$1"
6625 ])dnl
6626 dnl ---------------------------------------------------------------------------
6627 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
6628 dnl -------------
6629 AC_DEFUN([CF_RPATH_HACK],
6630 [
6631 AC_REQUIRE([CF_LD_RPATH_OPT])
6632 AC_MSG_CHECKING(for updated LDFLAGS)
6633 if test -n "$LD_RPATH_OPT" ; then
6634         AC_MSG_RESULT(maybe)
6635
6636         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
6637         cf_rpath_list="/usr/lib /lib"
6638         if test "$cf_ldd_prog" != no
6639         then
6640                 cf_rpath_oops=
6641
6642 AC_TRY_LINK([#include <stdio.h>],
6643                 [printf("Hello");],
6644                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
6645                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
6646
6647                 # If we passed the link-test, but get a "not found" on a given library,
6648                 # this could be due to inept reconfiguration of gcc to make it only
6649                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
6650                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
6651                 # /usr/local libraries.
6652                 if test -n "$cf_rpath_oops"
6653                 then
6654                         for cf_rpath_src in $cf_rpath_oops
6655                         do
6656                                 for cf_rpath_dir in \
6657                                         /usr/local \
6658                                         /usr/pkg \
6659                                         /opt/sfw
6660                                 do
6661                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
6662                                         then
6663                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
6664                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
6665                                                 break
6666                                         fi
6667                                 done
6668                         done
6669                 fi
6670         fi
6671
6672         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
6673
6674         CF_RPATH_HACK_2(LDFLAGS)
6675         CF_RPATH_HACK_2(LIBS)
6676
6677         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
6678 else
6679         AC_MSG_RESULT(no)
6680 fi
6681 AC_SUBST(EXTRA_LDFLAGS)
6682 ])dnl
6683 dnl ---------------------------------------------------------------------------
6684 dnl CF_RPATH_HACK_2 version: 7 updated: 2015/04/12 15:39:00
6685 dnl ---------------
6686 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
6687 dnl EXTRA_LDFLAGS for each -L option found.
6688 dnl
6689 dnl $cf_rpath_list contains a list of directories to ignore.
6690 dnl
6691 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
6692 dnl      but LIBS often has misplaced -L options.
6693 AC_DEFUN([CF_RPATH_HACK_2],
6694 [
6695 CF_VERBOSE(...checking $1 [$]$1)
6696
6697 cf_rpath_dst=
6698 for cf_rpath_src in [$]$1
6699 do
6700         case $cf_rpath_src in
6701         (-L*)
6702
6703                 # check if this refers to a directory which we will ignore
6704                 cf_rpath_skip=no
6705                 if test -n "$cf_rpath_list"
6706                 then
6707                         for cf_rpath_item in $cf_rpath_list
6708                         do
6709                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
6710                                 then
6711                                         cf_rpath_skip=yes
6712                                         break
6713                                 fi
6714                         done
6715                 fi
6716
6717                 if test "$cf_rpath_skip" = no
6718                 then
6719                         # transform the option
6720                         if test "$LD_RPATH_OPT" = "-R " ; then
6721                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
6722                         else
6723                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
6724                         fi
6725
6726                         # if we have not already added this, add it now
6727                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
6728                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
6729                         then
6730                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
6731                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
6732                         fi
6733                 fi
6734                 ;;
6735         esac
6736         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
6737 done
6738 $1=$cf_rpath_dst
6739
6740 CF_VERBOSE(...checked $1 [$]$1)
6741 AC_SUBST(EXTRA_LDFLAGS)
6742 ])dnl
6743 dnl ---------------------------------------------------------------------------
6744 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
6745 dnl ------------------
6746 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
6747 dnl and libraries which do not update those variables.
6748 dnl
6749 dnl $1 = name of current macro
6750 define([CF_SAVE_XTRA_FLAGS],
6751 [
6752 cf_save_LIBS_$1="$LIBS"
6753 cf_save_CFLAGS_$1="$CFLAGS"
6754 cf_save_CPPFLAGS_$1="$CPPFLAGS"
6755 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
6756 for cf_X_CFLAGS in $X_CFLAGS
6757 do
6758         case "x$cf_X_CFLAGS" in
6759         x-[[IUD]]*)
6760                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
6761                 ;;
6762         *)
6763                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
6764                 ;;
6765         esac
6766 done
6767 ])dnl
6768 dnl ---------------------------------------------------------------------------
6769 dnl CF_SHARED_OPTS version: 102 updated: 2020/08/22 18:17:19
6770 dnl --------------
6771 dnl --------------
6772 dnl Attempt to determine the appropriate CC/LD options for creating a shared
6773 dnl library.
6774 dnl
6775 dnl Notes:
6776 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
6777 dnl the build-tree, i.e., by making use of the libraries that are compiled in
6778 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
6779 dnl shared library since that can lead to unexpected results at runtime.
6780 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
6781 dnl libraries are compiled in ../../lib
6782 dnl
6783 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
6784 dnl to install symbolic links to the rel/abi versions of shared libraries.
6785 dnl
6786 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
6787 dnl version when making symbolic links.
6788 dnl
6789 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
6790 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
6791 dnl (ex: libncurses.so.<ver>).
6792 dnl
6793 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
6794 AC_DEFUN([CF_SHARED_OPTS],
6795 [
6796         AC_REQUIRE([CF_LD_RPATH_OPT])
6797
6798         RM_SHARED_OPTS=
6799         LOCAL_LDFLAGS=
6800         LOCAL_LDFLAGS2=
6801         LD_SHARED_OPTS=
6802         INSTALL_LIB="-m 644"
6803         : ${rel_builddir:=.}
6804
6805         shlibdir=$libdir
6806         AC_SUBST(shlibdir)
6807
6808         MAKE_DLLS="#"
6809         AC_SUBST(MAKE_DLLS)
6810
6811         cf_cv_do_symlinks=no
6812         cf_ld_rpath_opt=
6813         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
6814
6815         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
6816         AC_ARG_WITH(shlib-version,
6817         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
6818         [test -z "$withval" && withval=auto
6819         case $withval in
6820         (yes)
6821                 cf_cv_shlib_version=auto
6822                 ;;
6823         (rel|abi|auto)
6824                 cf_cv_shlib_version=$withval
6825                 ;;
6826         (*)
6827                 AC_MSG_RESULT($withval)
6828                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
6829                 ;;
6830         esac
6831         ],[cf_cv_shlib_version=auto])
6832         AC_MSG_RESULT($cf_cv_shlib_version)
6833
6834         cf_cv_rm_so_locs=no
6835         cf_try_cflags=
6836
6837         # Some less-capable ports of gcc support only -fpic
6838         CC_SHARED_OPTS=
6839
6840         cf_try_fPIC=no
6841         if test "$GCC" = yes
6842         then
6843                 cf_try_fPIC=yes
6844         else
6845                 case $cf_cv_system_name in
6846                 (*linux*)       # e.g., PGI compiler
6847                         cf_try_fPIC=yes
6848                         ;;
6849                 esac
6850         fi
6851
6852         if test "$cf_try_fPIC" = yes
6853         then
6854                 AC_MSG_CHECKING(which $CC option to use)
6855                 cf_save_CFLAGS="$CFLAGS"
6856                 for CC_SHARED_OPTS in -fPIC -fpic ''
6857                 do
6858                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
6859                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
6860                 done
6861                 AC_MSG_RESULT($CC_SHARED_OPTS)
6862                 CFLAGS="$cf_save_CFLAGS"
6863         fi
6864
6865         cf_cv_shlib_version_infix=no
6866
6867         case $cf_cv_system_name in
6868         (aix4.[3-9]*|aix[[5-7]]*)
6869                 if test "$GCC" = yes; then
6870                         CC_SHARED_OPTS='-Wl,-brtl'
6871                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
6872                 else
6873                         CC_SHARED_OPTS='-brtl'
6874                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
6875                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
6876                 fi
6877                 ;;
6878         (beos*)
6879                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
6880                 ;;
6881         (cygwin*)
6882                 CC_SHARED_OPTS=
6883                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6884                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6885                 cf_cv_shlib_version=cygdll
6886                 cf_cv_shlib_version_infix=cygdll
6887                 shlibdir=$bindir
6888                 MAKE_DLLS=
6889                 cat >mk_shared_lib.sh <<-CF_EOF
6890                 #!$SHELL
6891                 SHARED_LIB=\[$]1
6892                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6893                 shift
6894                 cat <<-EOF
6895                 Linking shared library
6896                 ** SHARED_LIB \[$]SHARED_LIB
6897                 ** IMPORT_LIB \[$]IMPORT_LIB
6898 EOF
6899                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6900 CF_EOF
6901                 chmod +x mk_shared_lib.sh
6902                 ;;
6903         (msys*)
6904                 CC_SHARED_OPTS=
6905                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6906                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6907                 cf_cv_shlib_version=msysdll
6908                 cf_cv_shlib_version_infix=msysdll
6909                 shlibdir=$bindir
6910                 MAKE_DLLS=
6911                 cat >mk_shared_lib.sh <<-CF_EOF
6912                 #!$SHELL
6913                 SHARED_LIB=\[$]1
6914                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6915                 shift
6916                 cat <<-EOF
6917                 Linking shared library
6918                 ** SHARED_LIB \[$]SHARED_LIB
6919                 ** IMPORT_LIB \[$]IMPORT_LIB
6920 EOF
6921                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6922 CF_EOF
6923                 chmod +x mk_shared_lib.sh
6924                 ;;
6925         (darwin*)
6926                 cf_try_cflags="no-cpp-precomp"
6927                 CC_SHARED_OPTS="-dynamic"
6928                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
6929                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
6930                 cf_cv_shlib_version_infix=yes
6931                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
6932                         cf_save_LDFLAGS=$LDFLAGS
6933                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
6934                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
6935                                 LDFLAGS=$cf_save_LDFLAGS])
6936                 if test $cf_cv_ldflags_search_paths_first = yes; then
6937                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
6938                 fi
6939                 ;;
6940         (hpux[[7-8]]*)
6941                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
6942                 if test "$GCC" != yes; then
6943                         CC_SHARED_OPTS='+Z'
6944                 fi
6945                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
6946                 INSTALL_LIB="-m 555"
6947                 ;;
6948         (hpux*)
6949                 # (tested with gcc 2.7.2 -- I don't have c89)
6950                 if test "$GCC" = yes; then
6951                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
6952                 else
6953                         CC_SHARED_OPTS='+Z'
6954                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
6955                 fi
6956                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
6957                 # HP-UX shared libraries must be executable, and should be
6958                 # readonly to exploit a quirk in the memory manager.
6959                 INSTALL_LIB="-m 555"
6960                 ;;
6961         (interix*)
6962                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6963                 if test "$cf_cv_shlib_version" = rel; then
6964                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
6965                 else
6966                         cf_shared_soname='`basename $[@]`'
6967                 fi
6968                 CC_SHARED_OPTS=
6969                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
6970                 ;;
6971         (irix*)
6972                 if test "$cf_cv_enable_rpath" = yes ; then
6973                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6974                 fi
6975                 # tested with IRIX 5.2 and 'cc'.
6976                 if test "$GCC" != yes; then
6977                         CC_SHARED_OPTS='-KPIC'
6978                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
6979                 else
6980                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
6981                 fi
6982                 cf_cv_rm_so_locs=yes
6983                 ;;
6984         (linux*|gnu*|k*bsd*-gnu)
6985                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
6986                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
6987                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6988                 fi
6989                 if test "$cf_cv_enable_rpath" = yes ; then
6990                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6991                 fi
6992                 CF_SHARED_SONAME
6993                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
6994                 ;;
6995         (mingw*msvc*)
6996                 cf_cv_shlib_version=msvcdll
6997                 cf_cv_shlib_version_infix=msvcdll
6998                 shlibdir=$bindir
6999                 MAKE_DLLS=
7000                 if test "$DFT_LWR_MODEL" = "shared" ; then
7001                         LOCAL_LDFLAGS="-link -dll"
7002                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7003                         EXTRA_LDFLAGS="-link -dll $EXTRA_LDFLAGS"
7004                 fi
7005                 CC_SHARED_OPTS=
7006                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ ${LD} [$]{CFLAGS}'
7007                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.lib"
7008                 cat >mk_shared_lib.sh <<-CF_EOF
7009                 #!$SHELL
7010                 SHARED_LIB=\[$]1
7011                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.lib/'\`
7012                 shift
7013                 my_ld=\[$]1
7014                 shift
7015                 cat <<-EOF
7016                 Linking shared library
7017                 ** SHARED LIB \$SHARED_LIB
7018                 ** IMPORT_LIB \$IMPORT_LIB
7019 EOF
7020                 args=\$(echo \[$]* | sed -E "s#-l(\w*)#\1.dll.lib#g" | sed -E "s#-L(\w*)#-LIBPATH:\1#g")
7021                 exec \$my_ld -DLL -IMPLIB:"\${IMPORT_LIB}" -OUT:"\${SHARED_LIB}" ${LDFLAGS} \$args
7022                 mv "\${IMPORT_LIB}" "\${IMPORT_LIB}"
7023 CF_EOF
7024                 chmod +x mk_shared_lib.sh
7025                 cat >mk_prog.sh <<-CF_EOF
7026                 #!$SHELL
7027                 shift
7028                 # Ignore first argument (compiler) and use LD (link.exe) unconditionally
7029                 LD="[$]LD"
7030                 clopts=()
7031                 ldopts=("/subsystem:console")
7032                 libs=()
7033                 isdll=0
7034                 while test \[$]# -gt 0; do
7035                         case "\[$]1" in
7036                                 -link)
7037                                         # ignore -link argument
7038                                         ;;
7039                                 -M[[TD]] | -M[[TD]]d)
7040                                         # ignore runtime-library option
7041                                         ;;
7042                                 -dll)
7043                                         isdll=1
7044                                         ;;
7045                                 -W* | -w*)
7046                                         # ignore warnings
7047                                         ;;
7048                                 -D*)
7049                                         clopts+=("\[$]1")
7050                                         ;;
7051                                 -I*)
7052                                         clopts+=("\[$]1")
7053                                         ;;
7054                                 -l*)
7055                                         libs+=("\`echo \"\[$]1\" | sed \"s/^-l//\"\`")
7056                                         ;;
7057                                 -L*)
7058                                         ldopts+=("\`echo \"\[$]1\" | sed \"s/^-L/-LIBPATH:/\"\`")
7059                                         ;;
7060                                 *.obj | *.o)
7061                                         ldopts+=("\[$]1")
7062                                         ;;
7063                                 -Wl,*)
7064                                         for linkarg in \`echo '\[$]1' | sed -e 's/-Wl,//' -e 's/,/ /'\`; do
7065                                                 ldopts+=("\[$]{linkarg}")
7066                                         done
7067                                         ;;
7068                                 *.lib)
7069                                         ldopts+=("\[$]1")
7070                                         ;;
7071                                 -o)
7072                                         shift
7073                                         ldopts+=("-out:\[$]1")
7074                                         ;;
7075                                 *)
7076                                         clopts+=("\[$]1")
7077                                         ldopts+=("\[$]1")
7078                                         ;;
7079                         esac
7080                         shift
7081                 done
7082                 if [[ "\$isdll" -ne 0 ]]; then
7083                         for lib in \[$]{libs[[*]]}; do
7084                                 ldopts+=("\[$]lib.dll.lib")
7085                         done
7086                 else
7087                         for lib in \[$]{libs[[*]]}; do
7088                                 ldopts+=("\[$]lib.lib")
7089                         done
7090                 fi
7091                 cat <<-EOF
7092                 Creating program
7093                 ** ld options:   "\[$]{ldopts[[@]]}"
7094 EOF
7095                 exec \[$]LD \[$]{ldopts[[@]]}
7096 CF_EOF
7097                 chmod +x mk_prog.sh
7098                 LINK_PROGS="$SHELL ${rel_builddir}/mk_prog.sh"
7099                 LINK_TESTS="$SHELL ${rel_builddir}/mk_prog.sh"
7100                 ;;
7101         (mingw*)
7102                 cf_cv_shlib_version=mingw
7103                 cf_cv_shlib_version_infix=mingw
7104                 shlibdir=$bindir
7105                 MAKE_DLLS=
7106                 if test "$DFT_LWR_MODEL" = "shared" ; then
7107                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
7108                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7109                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
7110                 fi
7111                 CC_SHARED_OPTS=
7112                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
7113                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
7114                 cat >mk_shared_lib.sh <<-CF_EOF
7115                 #!$SHELL
7116                 SHARED_LIB=\[$]1
7117                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
7118                 shift
7119                 cat <<-EOF
7120                 Linking shared library
7121                 ** SHARED_LIB \[$]SHARED_LIB
7122                 ** IMPORT_LIB \[$]IMPORT_LIB
7123 EOF
7124                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7125 CF_EOF
7126                 chmod +x mk_shared_lib.sh
7127                 ;;
7128         (openbsd[[2-9]].*|mirbsd*)
7129                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7130                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7131                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7132                 fi
7133                 if test "$cf_cv_enable_rpath" = yes ; then
7134                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7135                 fi
7136                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7137                 CF_SHARED_SONAME
7138                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7139                 ;;
7140         (nskJ*)
7141                 CC_SHARED_OPTS=
7142                 MK_SHARED_LIB='${LD} -Wshared -Weld=-export_all -o $[@]'
7143                 ;;
7144         (nskL*)
7145                 CC_SHARED_OPTS=
7146                 MK_SHARED_LIB='${LD} -Wshared -Wxld=-export_all -o $[@]'
7147                 ;;
7148         (nto-qnx*|openbsd*|freebsd[[12]].*)
7149                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7150                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
7151                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7152                 ;;
7153         (dragonfly*|freebsd*)
7154                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7155                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
7156                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
7157                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
7158                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7159                 fi
7160                 CF_SHARED_SONAME
7161                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7162                 ;;
7163         (netbsd*)
7164                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7165                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
7166                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
7167                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7168                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7169                         if test "$cf_cv_shlib_version" = auto; then
7170                         if test -f /usr/libexec/ld.elf_so; then
7171                                 cf_cv_shlib_version=abi
7172                         else
7173                                 cf_cv_shlib_version=rel
7174                         fi
7175                         fi
7176                         CF_SHARED_SONAME
7177                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
7178                 else
7179                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -o $[@]'
7180                 fi
7181                 ;;
7182         (osf*|mls+*)
7183                 # tested with OSF/1 V3.2 and 'cc'
7184                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
7185                 # link with shared libs).
7186                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
7187                 case $host_os in
7188                 (osf4*)
7189                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
7190                         ;;
7191                 esac
7192                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
7193                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7194                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7195                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7196                 fi
7197                 cf_cv_rm_so_locs=yes
7198                 ;;
7199         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
7200                 # tested with osr5.0.5
7201                 if test "$GCC" != yes; then
7202                         CC_SHARED_OPTS='-belf -KPIC'
7203                 fi
7204                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
7205                 if test "$cf_cv_enable_rpath" = yes ; then
7206                         # only way is to set LD_RUN_PATH but no switch for it
7207                         RUN_PATH=$libdir
7208                 fi
7209                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7210                 LINK_PROGS='LD_RUN_PATH=${libdir}'
7211                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
7212                 ;;
7213         (sunos4*)
7214                 # tested with SunOS 4.1.1 and gcc 2.7.0
7215                 if test "$GCC" != yes; then
7216                         CC_SHARED_OPTS='-KPIC'
7217                 fi
7218                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
7219                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7220                 ;;
7221         (solaris2*)
7222                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
7223                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
7224                 if test "$DFT_LWR_MODEL" = "shared" ; then
7225                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
7226                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7227                 fi
7228                 if test "$cf_cv_enable_rpath" = yes ; then
7229                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
7230                 fi
7231                 CF_SHARED_SONAME
7232                 if test "$GCC" != yes; then
7233                         cf_save_CFLAGS="$CFLAGS"
7234                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
7235                         do
7236                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
7237                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
7238                         done
7239                         CFLAGS="$cf_save_CFLAGS"
7240                         CC_SHARED_OPTS=$cf_shared_opts
7241                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
7242                 else
7243                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
7244                 fi
7245                 ;;
7246         (sysv5uw7*|unix_sv*)
7247                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
7248                 if test "$GCC" != yes; then
7249                         CC_SHARED_OPTS='-KPIC'
7250                 fi
7251                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
7252                 ;;
7253         (*)
7254                 CC_SHARED_OPTS='unknown'
7255                 MK_SHARED_LIB='echo unknown'
7256                 ;;
7257         esac
7258
7259         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
7260         case "$cf_cv_shlib_version" in
7261         (rel|abi)
7262                 case "$MK_SHARED_LIB" in
7263                 (*'-o $[@]')
7264                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
7265                         ;;
7266                 (*)
7267                         AC_MSG_WARN(ignored --with-shlib-version)
7268                         ;;
7269                 esac
7270                 ;;
7271         esac
7272
7273         if test -n "$cf_try_cflags"
7274         then
7275 cat > conftest.$ac_ext <<EOF
7276 #line __oline__ "${as_me:-configure}"
7277 #include <stdio.h>
7278 int main(int argc, char *argv[[]])
7279 {
7280         printf("hello\n");
7281         return (argv[[argc-1]] == 0) ;
7282 }
7283 EOF
7284                 cf_save_CFLAGS="$CFLAGS"
7285                 for cf_opt in $cf_try_cflags
7286                 do
7287                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
7288                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
7289                         if AC_TRY_EVAL(ac_compile); then
7290                                 AC_MSG_RESULT(yes)
7291                                 cf_save_CFLAGS="$CFLAGS"
7292                         else
7293                                 AC_MSG_RESULT(no)
7294                         fi
7295                 done
7296                 CFLAGS="$cf_save_CFLAGS"
7297         fi
7298
7299
7300         # RPATH_LIST is a colon-separated list of directories
7301         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
7302         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
7303
7304         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
7305
7306         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
7307         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7308
7309         AC_SUBST(CC_SHARED_OPTS)
7310         AC_SUBST(LD_RPATH_OPT)
7311         AC_SUBST(LD_SHARED_OPTS)
7312         AC_SUBST(MK_SHARED_LIB)
7313         AC_SUBST(RM_SHARED_OPTS)
7314
7315         AC_SUBST(LINK_PROGS)
7316         AC_SUBST(LINK_TESTS)
7317
7318         AC_SUBST(EXTRA_LDFLAGS)
7319         AC_SUBST(LOCAL_LDFLAGS)
7320         AC_SUBST(LOCAL_LDFLAGS2)
7321
7322         AC_SUBST(INSTALL_LIB)
7323         AC_SUBST(RPATH_LIST)
7324 ])dnl
7325 dnl ---------------------------------------------------------------------------
7326 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
7327 dnl ----------------
7328 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
7329 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
7330 dnl option.
7331 dnl
7332 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
7333 dnl If missing, use "rel".
7334 define([CF_SHARED_SONAME],
7335 [
7336         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
7337         if test "$cf_cv_shlib_version" = rel; then
7338                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
7339         else
7340                 cf_cv_shared_soname='`basename $[@]`'
7341         fi
7342 ])
7343 dnl ---------------------------------------------------------------------------
7344 dnl CF_SIGWINCH version: 3 updated: 2020/03/10 18:53:47
7345 dnl -----------
7346 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
7347 dnl programs need this test).
7348 dnl
7349 dnl This is really a Mac OS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
7350 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
7351 dnl winsize declaration is left alone - we may revisit this if Apple choose to
7352 dnl break that part of the interface as well.
7353 AC_DEFUN([CF_SIGWINCH],
7354 [
7355 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
7356         AC_TRY_COMPILE([
7357 #include <sys/types.h>
7358 #include <sys/signal.h>
7359 ],[int x = SIGWINCH; (void)x],
7360         [cf_cv_define_sigwinch=yes],
7361         [AC_TRY_COMPILE([
7362 #undef _XOPEN_SOURCE
7363 #undef _POSIX_SOURCE
7364 #undef _POSIX_C_SOURCE
7365 #include <sys/types.h>
7366 #include <sys/signal.h>
7367 ],[int x = SIGWINCH; (void)x],
7368         [cf_cv_define_sigwinch=maybe],
7369         [cf_cv_define_sigwinch=no])
7370 ])
7371 ])
7372
7373 if test "$cf_cv_define_sigwinch" = maybe ; then
7374 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
7375 cf_cv_fixup_sigwinch=unknown
7376 cf_sigwinch=32
7377 while test $cf_sigwinch != 1
7378 do
7379         AC_TRY_COMPILE([
7380 #undef _XOPEN_SOURCE
7381 #undef _POSIX_SOURCE
7382 #undef _POSIX_C_SOURCE
7383 #include <sys/types.h>
7384 #include <sys/signal.h>
7385 ],[
7386 #if SIGWINCH != $cf_sigwinch
7387 make an error
7388 #endif
7389 int x = SIGWINCH; (void)x],
7390         [cf_cv_fixup_sigwinch=$cf_sigwinch
7391          break])
7392
7393 cf_sigwinch=`expr $cf_sigwinch - 1`
7394 done
7395 ])
7396
7397         if test "$cf_cv_fixup_sigwinch" != unknown ; then
7398                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
7399         fi
7400 fi
7401 ])dnl
7402 dnl ---------------------------------------------------------------------------
7403 dnl CF_SIG_ATOMIC_T version: 5 updated: 2020/03/10 18:53:47
7404 dnl ---------------
7405 dnl signal handler, but there are some gcc dependencies in that recommendation.
7406 dnl Try anyway.
7407 AC_DEFUN([CF_SIG_ATOMIC_T],
7408 [
7409 AC_MSG_CHECKING(for signal global datatype)
7410 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
7411         for cf_type in \
7412                 "volatile sig_atomic_t" \
7413                 "sig_atomic_t" \
7414                 "int"
7415         do
7416         AC_TRY_COMPILE([
7417 #include <sys/types.h>
7418 #include <signal.h>
7419 #include <stdio.h>
7420
7421 extern $cf_type x;
7422 $cf_type x;
7423 static void handler(int sig)
7424 {
7425         (void)sig;
7426         x = 5;
7427 }],
7428                 [signal(SIGINT, handler);
7429                  x = 1],
7430                 [cf_cv_sig_atomic_t=$cf_type],
7431                 [cf_cv_sig_atomic_t=no])
7432                 test "$cf_cv_sig_atomic_t" != no && break
7433         done
7434         ])
7435 AC_MSG_RESULT($cf_cv_sig_atomic_t)
7436 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
7437 ])dnl
7438 dnl ---------------------------------------------------------------------------
7439 dnl CF_SIZECHANGE version: 16 updated: 2020/03/19 20:46:13
7440 dnl -------------
7441 dnl Check for definitions & structures needed for window size-changing
7442 dnl
7443 dnl https://stackoverflow.com/questions/18878141/difference-between-structures-ttysize-and-winsize/50769952#50769952
7444 AC_DEFUN([CF_SIZECHANGE],
7445 [
7446 AC_REQUIRE([CF_STRUCT_TERMIOS])
7447 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
7448         cf_cv_sizechange=unknown
7449         cf_save_CPPFLAGS="$CPPFLAGS"
7450
7451 for cf_opts in "" "NEED_PTEM_H"
7452 do
7453
7454         CPPFLAGS="$cf_save_CPPFLAGS"
7455         if test -n "$cf_opts"
7456         then
7457                 CF_APPEND_TEXT(CPPFLAGS,-D$cf_opts)
7458         fi
7459         AC_TRY_COMPILE([#include <sys/types.h>
7460 #ifdef HAVE_TERMIOS_H
7461 #include <termios.h>
7462 #else
7463 #ifdef HAVE_TERMIO_H
7464 #include <termio.h>
7465 #endif
7466 #endif
7467
7468 #ifdef NEED_PTEM_H
7469 /* This is a workaround for SCO:  they neglected to define struct winsize in
7470  * termios.h -- it's only in termio.h and ptem.h
7471  */
7472 #include <sys/stream.h>
7473 #include <sys/ptem.h>
7474 #endif
7475
7476 #ifdef HAVE_SYS_IOCTL_H
7477 #include <sys/ioctl.h>
7478 #endif
7479 ],[
7480 #ifdef TIOCGSIZE
7481         struct ttysize win;     /* SunOS 3.0... */
7482         int y = win.ts_lines = 2;
7483         int x = win.ts_cols = 1;
7484         (void)y;
7485         (void)x;
7486 #else
7487 #ifdef TIOCGWINSZ
7488         struct winsize win;     /* everything else */
7489         int y = win.ws_row = 2;
7490         int x = win.ws_col = 1;
7491         (void)y;
7492         (void)x;
7493 #else
7494         no TIOCGSIZE or TIOCGWINSZ
7495 #endif /* TIOCGWINSZ */
7496 #endif /* TIOCGSIZE */
7497         ],
7498         [cf_cv_sizechange=yes],
7499         [cf_cv_sizechange=no])
7500
7501         CPPFLAGS="$cf_save_CPPFLAGS"
7502         if test "$cf_cv_sizechange" = yes ; then
7503                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
7504                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
7505                 break
7506         fi
7507 done
7508 ])
7509 if test "$cf_cv_sizechange" != no ; then
7510         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechange declarations are provided])
7511         case $cf_cv_sizechange in
7512         (NEED*)
7513                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
7514                 ;;
7515         esac
7516 fi
7517 ])dnl
7518 dnl ---------------------------------------------------------------------------
7519 dnl CF_SRC_MODULES version: 32 updated: 2020/03/07 20:05:14
7520 dnl --------------
7521 dnl For each parameter, test if the source-directory exists, and if it contains
7522 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
7523 dnl use in CF_LIB_RULES.
7524 dnl
7525 dnl This uses the configured value to make the lists SRC_SUBDIRS and
7526 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
7527 AC_DEFUN([CF_SRC_MODULES],
7528 [
7529 AC_REQUIRE([CF_CHECK_GNAT_VERSION])
7530 AC_MSG_CHECKING(for src modules)
7531
7532 # dependencies and linker-arguments for test-programs
7533 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
7534 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
7535 if test "$DFT_LWR_MODEL" = "libtool"; then
7536         TEST_ARGS="${TEST_DEPS}"
7537         TEST_ARG2="${TEST_DEP2}"
7538 else
7539         TEST_ARGS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
7540         TEST_ARG2="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARG2"
7541 fi
7542
7543 PC_MODULES_TO_MAKE="ncurses${USE_ARG_SUFFIX}"
7544 cf_cv_src_modules=
7545 for cf_dir in $1
7546 do
7547         if test -f $srcdir/$cf_dir/modules; then
7548
7549                 # We may/may not have tack in the distribution, though the
7550                 # makefile is.
7551                 if test $cf_dir = tack ; then
7552                         if test "x$cf_with_tack" != "xyes"; then
7553                                 continue
7554                         fi
7555                 fi
7556
7557                 if test -z "$cf_cv_src_modules"; then
7558                         cf_cv_src_modules=$cf_dir
7559                 else
7560                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
7561                 fi
7562
7563                 # Make the ncurses_cfg.h file record the library interface files as
7564                 # well.  These are header files that are the same name as their
7565                 # directory.  Ncurses is the only library that does not follow
7566                 # that pattern.
7567                 if test $cf_dir = tack ; then
7568                         continue
7569                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
7570                         CF_UPPER(cf_have_include,$cf_dir)
7571                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
7572                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
7573                         CF_MAP_LIB_BASENAME(TEST_ROOT,$cf_dir)
7574                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEPS"
7575                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEP2"
7576                         if test "$DFT_LWR_MODEL" = "libtool"; then
7577                                 TEST_ARGS="${TEST_DEPS}"
7578                                 TEST_ARG2="${TEST_DEP2}"
7579                         else
7580                                 TEST_ARGS="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARGS"
7581                                 TEST_ARG2="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARG2"
7582                         fi
7583                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${USE_ARG_SUFFIX}"
7584                 fi
7585         fi
7586 done
7587 AC_MSG_RESULT($cf_cv_src_modules)
7588
7589 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
7590 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
7591
7592 AC_SUBST(TEST_ARGS)
7593 AC_SUBST(TEST_DEPS)
7594
7595 AC_SUBST(TEST_ARG2)
7596 AC_SUBST(TEST_DEP2)
7597
7598 SRC_SUBDIRS=
7599 if test "x$cf_with_manpages" != xno ; then
7600         SRC_SUBDIRS="$SRC_SUBDIRS man"
7601 fi
7602 SRC_SUBDIRS="$SRC_SUBDIRS include"
7603 for cf_dir in $cf_cv_src_modules
7604 do
7605         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
7606 done
7607 if test "x$cf_with_tests" != "xno" ; then
7608         SRC_SUBDIRS="$SRC_SUBDIRS test"
7609 fi
7610 # always make this, to install the ncurses-config script
7611 SRC_SUBDIRS="$SRC_SUBDIRS misc"
7612 if test "$cf_with_cxx_binding" != no; then
7613         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${USE_ARG_SUFFIX}"
7614         SRC_SUBDIRS="$SRC_SUBDIRS c++"
7615 fi
7616
7617 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
7618 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
7619
7620 AC_SUBST(PC_MODULES_TO_MAKE)
7621
7622 ADA_SUBDIRS=
7623 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
7624         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
7625         ADA_SUBDIRS="gen src"
7626         if test "x$cf_with_tests" != "xno" ; then
7627                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
7628         fi
7629 fi
7630
7631 SUB_MAKEFILES=
7632 for cf_dir in $SRC_SUBDIRS
7633 do
7634         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
7635 done
7636
7637 if test -n "$ADA_SUBDIRS"; then
7638         for cf_dir in $ADA_SUBDIRS
7639         do
7640                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
7641         done
7642         AC_SUBST(ADA_SUBDIRS)
7643 fi
7644 ])dnl
7645 dnl ---------------------------------------------------------------------------
7646 dnl CF_STDCPP_LIBRARY version: 11 updated: 2015/10/17 19:03:33
7647 dnl -----------------
7648 dnl Check for -lstdc++, which is GNU's standard C++ library.
7649 dnl If $CXXLIBS is set, add that to the libraries used for test-linking.
7650 dnl If -lstdc++ was not already added to $LIBS or $CXXLIBS, and is needed,
7651 dnl add it to $CXXLIBS.
7652 AC_DEFUN([CF_STDCPP_LIBRARY],
7653 [
7654 if test -n "$GXX" ; then
7655
7656         cf_save="$LIBS"
7657         LIBS="$LIBS $CXXLIBS"
7658         AC_MSG_CHECKING(if we already have C++ library)
7659         AC_TRY_LINK([
7660                         #include <iostream>],[
7661                         std::cout << "Hello World!" << std::endl;],
7662                 [cf_have_libstdcpp=yes],
7663                 [cf_have_libstdcpp=no])
7664         AC_MSG_RESULT($cf_have_libstdcpp)
7665         LIBS="$cf_save"
7666
7667         if test $cf_have_libstdcpp != yes
7668         then
7669                 case $cf_cv_system_name in
7670                 (os2*)
7671                         if test -z "`g++ -dM -E - < /dev/null | grep __KLIBC__`"; then
7672                                 cf_stdcpp_libname=stdcpp
7673                         else
7674                                 cf_stdcpp_libname=stdc++
7675                         fi
7676                         ;;
7677                 (*)
7678                         cf_stdcpp_libname=stdc++
7679                         ;;
7680                 esac
7681
7682                 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
7683                         cf_save="$LIBS"
7684                         LIBS="$LIBS $CXXLIBS"
7685                         CF_ADD_LIB($cf_stdcpp_libname)
7686                 AC_TRY_LINK([
7687                                 #include <iostream>],[
7688                                 std::cout << "Hello World!" << std::endl;],
7689                         [cf_cv_libstdcpp=yes],
7690                         [cf_cv_libstdcpp=no])
7691                         LIBS="$cf_save"
7692                 ])
7693                 test "$cf_cv_libstdcpp" = yes && { CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS) }
7694         fi
7695 fi
7696 ])dnl
7697 dnl ---------------------------------------------------------------------------
7698 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
7699 dnl --------------
7700 dnl     Remove "-g" option from the compiler options
7701 AC_DEFUN([CF_STRIP_G_OPT],
7702 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
7703 dnl ---------------------------------------------------------------------------
7704 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
7705 dnl -------------------
7706 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
7707 dnl do this if we've found the sigaction function.
7708 AC_DEFUN([CF_STRUCT_SIGACTION],[
7709 AC_REQUIRE([CF_XOPEN_SOURCE])
7710
7711 if test "$ac_cv_func_sigaction" = yes; then
7712 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
7713 AC_TRY_COMPILE([
7714 #include <sys/types.h>
7715 #include <signal.h>],
7716         [struct sigaction act],
7717         [sigact_bad=no],
7718         [
7719 AC_TRY_COMPILE([
7720 #define _POSIX_SOURCE
7721 #include <sys/types.h>
7722 #include <signal.h>],
7723         [struct sigaction act],
7724         [sigact_bad=yes
7725          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
7726          [sigact_bad=unknown])])
7727 AC_MSG_RESULT($sigact_bad)
7728 fi
7729 ])dnl
7730 dnl ---------------------------------------------------------------------------
7731 dnl CF_STRUCT_TERMIOS version: 11 updated: 2020/03/19 20:46:13
7732 dnl -----------------
7733 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
7734 AC_DEFUN([CF_STRUCT_TERMIOS],[
7735 AC_REQUIRE([CF_XOPEN_SOURCE])
7736
7737 AC_CHECK_HEADERS( \
7738 termio.h \
7739 termios.h \
7740 unistd.h \
7741 sys/ioctl.h \
7742 sys/termio.h \
7743 )
7744
7745 if test "$ac_cv_header_termios_h" = yes ; then
7746         case "$CFLAGS $CPPFLAGS" in
7747         (*-D_POSIX_SOURCE*)
7748                 termios_bad=dunno ;;
7749         (*)     termios_bad=maybe ;;
7750         esac
7751         if test "$termios_bad" = maybe ; then
7752         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
7753         AC_TRY_COMPILE([#include <termios.h>],
7754                 [struct termios foo; int x = foo.c_iflag = 1; (void)x],
7755                 termios_bad=no, [
7756                 AC_TRY_COMPILE([
7757 #define _POSIX_SOURCE
7758 #include <termios.h>],
7759                         [struct termios foo; int x = foo.c_iflag = 2; (void)x],
7760                         termios_bad=unknown,
7761                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
7762                         ])
7763         AC_MSG_RESULT($termios_bad)
7764         fi
7765 fi
7766 ])dnl
7767 dnl ---------------------------------------------------------------------------
7768 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
7769 dnl --------------
7770 dnl Construct a search-list for a nonstandard header/lib-file
7771 dnl     $1 = the variable to return as result
7772 dnl     $2 = the package name
7773 dnl     $3 = the subdirectory, e.g., bin, include or lib
7774 AC_DEFUN([CF_SUBDIR_PATH],
7775 [
7776 $1=
7777
7778 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
7779
7780 for cf_subdir_prefix in \
7781         /usr \
7782         /usr/local \
7783         /usr/pkg \
7784         /opt \
7785         /opt/local \
7786         [$]HOME
7787 do
7788         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
7789 done
7790 ])dnl
7791 dnl ---------------------------------------------------------------------------
7792 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
7793 dnl -----------
7794 dnl     Shorthand macro for substituting things that the user may override
7795 dnl     with an environment variable.
7796 dnl
7797 dnl     $1 = condition to pass to "test"
7798 dnl     $2 = environment variable
7799 dnl     $3 = value if the test succeeds
7800 dnl     $4 = value if the test fails
7801 AC_DEFUN([CF_SUBST_IF],
7802 [
7803 if test $1 ; then
7804         $2=$3
7805 ifelse($4,,,[else
7806         $2=$4])
7807 fi
7808 AC_SUBST($2)
7809 ])dnl
7810 dnl ---------------------------------------------------------------------------
7811 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
7812 dnl ------------------------
7813 dnl Get the version-number for use in shared-library naming, etc.
7814 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
7815 [
7816 AC_REQUIRE([CF_PROG_EGREP])
7817 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
7818 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
7819 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
7820 cf_cv_abi_version=${NCURSES_MAJOR}
7821 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
7822 dnl Show the computed version, for logging
7823 cf_cv_timestamp=`date`
7824 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
7825 dnl We need these values in the generated headers
7826 AC_SUBST(NCURSES_MAJOR)
7827 AC_SUBST(NCURSES_MINOR)
7828 AC_SUBST(NCURSES_PATCH)
7829 dnl We need these values in the generated makefiles
7830 AC_SUBST(cf_cv_rel_version)
7831 AC_SUBST(cf_cv_abi_version)
7832 AC_SUBST(cf_cv_builtin_bool)
7833 AC_SUBST(cf_cv_header_stdbool_h)
7834 AC_SUBST(cf_cv_type_of_bool)dnl
7835 ])dnl
7836 dnl ---------------------------------------------------------------------------
7837 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
7838 dnl ------------------
7839 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
7840 dnl older SCO configurations.
7841 AC_DEFUN([CF_SYS_TIME_SELECT],
7842 [
7843 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
7844 AC_CACHE_VAL(cf_cv_sys_time_select,[
7845 AC_TRY_COMPILE([
7846 #include <sys/types.h>
7847 #ifdef HAVE_SYS_TIME_H
7848 #include <sys/time.h>
7849 #endif
7850 #ifdef HAVE_SYS_SELECT_H
7851 #include <sys/select.h>
7852 #endif
7853 ],[],[cf_cv_sys_time_select=yes],
7854          [cf_cv_sys_time_select=no])
7855          ])
7856 AC_MSG_RESULT($cf_cv_sys_time_select)
7857 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
7858 ])dnl
7859 dnl ---------------------------------------------------------------------------
7860 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
7861 dnl ---------------
7862 dnl Define a top_builddir symbol, for applications that need an absolute path.
7863 AC_DEFUN([CF_TOP_BUILDDIR],
7864 [
7865 top_builddir=ifelse($1,,`pwd`,$1)
7866 AC_SUBST(top_builddir)
7867 ])dnl
7868 dnl ---------------------------------------------------------------------------
7869 dnl CF_TRY_PKG_CONFIG version: 5 updated: 2013/07/06 21:27:06
7870 dnl -----------------
7871 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
7872 dnl available in that form.
7873 dnl
7874 dnl $1 = package name
7875 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
7876 dnl $3 = logic to use if pkg-config does not have the package
7877 AC_DEFUN([CF_TRY_PKG_CONFIG],[
7878 AC_REQUIRE([CF_PKG_CONFIG])
7879
7880 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists $1; then
7881         CF_VERBOSE(found package $1)
7882         cf_pkgconfig_incs="`$PKG_CONFIG --cflags $1 2>/dev/null`"
7883         cf_pkgconfig_libs="`$PKG_CONFIG --libs   $1 2>/dev/null`"
7884         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
7885         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
7886         CF_ADD_CFLAGS($cf_pkgconfig_incs)
7887         CF_ADD_LIBS($cf_pkgconfig_libs)
7888         ifelse([$2],,:,[$2])
7889 else
7890         cf_pkgconfig_incs=
7891         cf_pkgconfig_libs=
7892         ifelse([$3],,:,[$3])
7893 fi
7894 ])
7895 dnl ---------------------------------------------------------------------------
7896 dnl CF_TRY_XOPEN_SOURCE version: 2 updated: 2018/06/20 20:23:13
7897 dnl -------------------
7898 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
7899 dnl can define it successfully.
7900 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
7901 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
7902         AC_TRY_COMPILE([
7903 #include <stdlib.h>
7904 #include <string.h>
7905 #include <sys/types.h>
7906 ],[
7907 #ifndef _XOPEN_SOURCE
7908 make an error
7909 #endif],
7910         [cf_cv_xopen_source=no],
7911         [cf_save="$CPPFLAGS"
7912          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
7913          AC_TRY_COMPILE([
7914 #include <stdlib.h>
7915 #include <string.h>
7916 #include <sys/types.h>
7917 ],[
7918 #ifdef _XOPEN_SOURCE
7919 make an error
7920 #endif],
7921         [cf_cv_xopen_source=no],
7922         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
7923         CPPFLAGS="$cf_save"
7924         ])
7925 ])
7926
7927 if test "$cf_cv_xopen_source" != no ; then
7928         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
7929         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
7930         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
7931         CF_ADD_CFLAGS($cf_temp_xopen_source)
7932 fi
7933 ])
7934 dnl ---------------------------------------------------------------------------
7935 dnl CF_TYPEOF_CHTYPE version: 10 updated: 2017/01/21 11:06:25
7936 dnl ----------------
7937 dnl Determine the type we should use for chtype (and attr_t, which is treated
7938 dnl as the same thing).  We want around 32 bits, so on most machines want a
7939 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
7940 dnl wide characters, we have to have a type compatible with that, as well.
7941 AC_DEFUN([CF_TYPEOF_CHTYPE],
7942 [
7943 AC_MSG_CHECKING([for type of chtype])
7944 AC_CACHE_VAL(cf_cv_typeof_chtype,[
7945                 AC_TRY_RUN([
7946 #define WANT_BITS 31
7947 #include <stdio.h>
7948 int main(void)
7949 {
7950         FILE *fp = fopen("cf_test.out", "w");
7951         if (fp != 0) {
7952                 char *result = "long";
7953                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
7954                         int n;
7955                         unsigned int x, y;
7956                         for (n = 0; n < WANT_BITS; n++) {
7957                                 x = (1 << n);
7958                                 y = (x >> n);
7959                                 if (y != 1 || x == 0) {
7960                                         x = 0;
7961                                         break;
7962                                 }
7963                         }
7964                         /*
7965                          * If x is nonzero, an int is big enough for the bits
7966                          * that we want.
7967                          */
7968                         result = (x != 0) ? "int" : "long";
7969                 }
7970                 fputs(result, fp);
7971                 fclose(fp);
7972         }
7973         ${cf_cv_main_return:-return}(0);
7974 }
7975                 ],
7976                 [cf_cv_typeof_chtype=`cat cf_test.out`],
7977                 [cf_cv_typeof_chtype=long],
7978                 [cf_cv_typeof_chtype=long])
7979                 rm -f cf_test.out
7980         ])
7981 AC_MSG_RESULT($cf_cv_typeof_chtype)
7982
7983 AC_SUBST(cf_cv_typeof_chtype)
7984 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
7985 ])dnl
7986 dnl ---------------------------------------------------------------------------
7987 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
7988 dnl -----------------
7989 dnl
7990 AC_DEFUN([CF_TYPE_SIGACTION],
7991 [
7992 AC_MSG_CHECKING([for type sigaction_t])
7993 AC_CACHE_VAL(cf_cv_type_sigaction,[
7994         AC_TRY_COMPILE([
7995 #include <signal.h>],
7996                 [sigaction_t x],
7997                 [cf_cv_type_sigaction=yes],
7998                 [cf_cv_type_sigaction=no])])
7999 AC_MSG_RESULT($cf_cv_type_sigaction)
8000 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
8001 ])dnl
8002 dnl ---------------------------------------------------------------------------
8003 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
8004 dnl --------------------
8005 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
8006 dnl won't, but they're still there.
8007 AC_DEFUN([CF_UNSIGNED_LITERALS],
8008 [
8009 AC_MSG_CHECKING([if unsigned literals are legal])
8010 AC_CACHE_VAL(cf_cv_unsigned_literals,[
8011         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
8012                 [cf_cv_unsigned_literals=yes],
8013                 [cf_cv_unsigned_literals=no])
8014         ])
8015 AC_MSG_RESULT($cf_cv_unsigned_literals)
8016 ])dnl
8017 dnl ---------------------------------------------------------------------------
8018 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
8019 dnl --------
8020 dnl Make an uppercase version of a variable
8021 dnl $1=uppercase($2)
8022 AC_DEFUN([CF_UPPER],
8023 [
8024 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
8025 ])dnl
8026 dnl ---------------------------------------------------------------------------
8027 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
8028 dnl -----------
8029 dnl Check for multibyte support, and if not found, utf8 compatibility library
8030 AC_DEFUN([CF_UTF8_LIB],
8031 [
8032 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
8033         cf_save_LIBS="$LIBS"
8034         AC_TRY_LINK([
8035 #include <stdlib.h>],[putwc(0,0);],
8036         [cf_cv_utf8_lib=yes],
8037         [CF_FIND_LINKAGE([
8038 #include <libutf8.h>],[putwc(0,0);],utf8,
8039                 [cf_cv_utf8_lib=add-on],
8040                 [cf_cv_utf8_lib=no])
8041 ])])
8042
8043 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
8044 # ncurses/ncursesw:
8045 if test "$cf_cv_utf8_lib" = "add-on" ; then
8046         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
8047         CF_ADD_INCDIR($cf_cv_header_path_utf8)
8048         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
8049         CF_ADD_LIBS($cf_cv_library_file_utf8)
8050 fi
8051 ])dnl
8052 dnl ---------------------------------------------------------------------------
8053 dnl CF_VA_COPY version: 6 updated: 2018/12/04 18:14:25
8054 dnl ----------
8055 dnl check for va_copy, part of stdarg.h starting with ISO C 1999.
8056 dnl Also, workaround for glibc's __va_copy, by checking for both.
8057 dnl Finally, try to accommodate pre-ISO C 1999 headers.
8058 AC_DEFUN([CF_VA_COPY],[
8059 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
8060 AC_TRY_LINK([
8061 #include <stdarg.h>
8062 ],[
8063         static va_list dst;
8064         static va_list src;
8065         va_copy(dst, src)],
8066         cf_cv_have_va_copy=yes,
8067         cf_cv_have_va_copy=no)])
8068
8069 if test "$cf_cv_have_va_copy" = yes;
8070 then
8071         AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
8072 else # !cf_cv_have_va_copy
8073
8074 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
8075 AC_TRY_LINK([
8076 #include <stdarg.h>
8077 ],[
8078         static va_list dst;
8079         static va_list src;
8080         __va_copy(dst, src)],
8081         cf_cv_have___va_copy=yes,
8082         cf_cv_have___va_copy=no)])
8083
8084 if test "$cf_cv_have___va_copy" = yes
8085 then
8086         AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
8087 else # !cf_cv_have___va_copy
8088
8089 AC_CACHE_CHECK(for __builtin_va_copy, cf_cv_have___builtin_va_copy,[
8090 AC_TRY_LINK([
8091 #include <stdarg.h>
8092 ],[
8093         static va_list dst;
8094         static va_list src;
8095         __builtin_va_copy(dst, src)],
8096         cf_cv_have___builtin_va_copy=yes,
8097         cf_cv_have___builtin_va_copy=no)])
8098
8099 test "$cf_cv_have___builtin_va_copy" = yes &&
8100         AC_DEFINE(HAVE___BUILTIN_VA_COPY,1,[Define to 1 if we have __builtin_va_copy])
8101
8102 fi # cf_cv_have___va_copy
8103
8104 fi # cf_cv_have_va_copy
8105
8106 case "${cf_cv_have_va_copy}${cf_cv_have___va_copy}${cf_cv_have___builtin_va_copy}" in
8107 (*yes*)
8108         ;;
8109
8110 (*)
8111         AC_CACHE_CHECK(if we can simply copy va_list, cf_cv_pointer_va_list,[
8112 AC_TRY_LINK([
8113 #include <stdarg.h>
8114 ],[
8115         va_list dst;
8116         va_list src;
8117         dst = src],
8118         cf_cv_pointer_va_list=yes,
8119         cf_cv_pointer_va_list=no)])
8120
8121         if test "$cf_cv_pointer_va_list" = no
8122         then
8123                 AC_CACHE_CHECK(if we can copy va_list indirectly, cf_cv_array_va_list,[
8124 AC_TRY_LINK([
8125 #include <stdarg.h>
8126 ],[
8127         va_list dst;
8128         va_list src;
8129         *dst = *src],
8130                         cf_cv_array_va_list=yes,
8131                         cf_cv_array_va_list=no)])
8132                 test "$cf_cv_array_va_list" = yes && AC_DEFINE(ARRAY_VA_LIST,1,[Define to 1 if we can copy va_list indirectly])
8133         fi
8134         ;;
8135 esac
8136 ])
8137 dnl ---------------------------------------------------------------------------
8138 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
8139 dnl ----------
8140 dnl Use AC_VERBOSE w/o the warnings
8141 AC_DEFUN([CF_VERBOSE],
8142 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
8143 CF_MSG_LOG([$1])
8144 ])dnl
8145 dnl ---------------------------------------------------------------------------
8146 dnl CF_VERSION_INFO version: 7 updated: 2015/04/17 21:13:04
8147 dnl ---------------
8148 dnl Define several useful symbols derived from the VERSION file.  A separate
8149 dnl file is preferred to embedding the version numbers in various scripts.
8150 dnl (automake is a textbook-example of why the latter is a bad idea, but there
8151 dnl are others).
8152 dnl
8153 dnl The file contents are:
8154 dnl     libtool-version release-version patch-version
8155 dnl or
8156 dnl     release-version
8157 dnl where
8158 dnl     libtool-version (see ?) consists of 3 integers separated by '.'
8159 dnl     release-version consists of a major version and minor version
8160 dnl             separated by '.', optionally followed by a patch-version
8161 dnl             separated by '-'.  The minor version need not be an
8162 dnl             integer (but it is preferred).
8163 dnl     patch-version is an integer in the form yyyymmdd, so ifdef's and
8164 dnl             scripts can easily compare versions.
8165 dnl
8166 dnl If libtool is used, the first form is required, since CF_WITH_LIBTOOL
8167 dnl simply extracts the first field using 'cut -f1'.
8168 dnl
8169 dnl Optional parameters:
8170 dnl $1 = internal name for package
8171 dnl $2 = external name for package
8172 AC_DEFUN([CF_VERSION_INFO],
8173 [
8174 if test -f $srcdir/VERSION ; then
8175         AC_MSG_CHECKING(for package version)
8176
8177         # if there are not enough fields, cut returns the last one...
8178         cf_field1=`sed -e '2,$d' $srcdir/VERSION|cut -f1`
8179         cf_field2=`sed -e '2,$d' $srcdir/VERSION|cut -f2`
8180         cf_field3=`sed -e '2,$d' $srcdir/VERSION|cut -f3`
8181
8182         # this is how CF_BUNDLED_INTL uses $VERSION:
8183         VERSION="$cf_field1"
8184
8185         VERSION_MAJOR=`echo "$cf_field2" | sed -e 's/\..*//'`
8186         test -z "$VERSION_MAJOR" && AC_MSG_ERROR(missing major-version)
8187
8188         VERSION_MINOR=`echo "$cf_field2" | sed -e 's/^[[^.]]*\.//' -e 's/-.*//'`
8189         test -z "$VERSION_MINOR" && AC_MSG_ERROR(missing minor-version)
8190
8191         AC_MSG_RESULT(${VERSION_MAJOR}.${VERSION_MINOR})
8192
8193         AC_MSG_CHECKING(for package patch date)
8194         VERSION_PATCH=`echo "$cf_field3" | sed -e 's/^[[^-]]*-//'`
8195         case .$VERSION_PATCH in
8196         (.)
8197                 AC_MSG_ERROR(missing patch-date $VERSION_PATCH)
8198                 ;;
8199         (.[[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]])
8200                 ;;
8201         (*)
8202                 AC_MSG_ERROR(illegal patch-date $VERSION_PATCH)
8203                 ;;
8204         esac
8205         AC_MSG_RESULT($VERSION_PATCH)
8206 else
8207         AC_MSG_ERROR(did not find $srcdir/VERSION)
8208 fi
8209
8210 # show the actual data that we have for versions:
8211 CF_VERBOSE(ABI VERSION $VERSION)
8212 CF_VERBOSE(VERSION_MAJOR $VERSION_MAJOR)
8213 CF_VERBOSE(VERSION_MINOR $VERSION_MINOR)
8214 CF_VERBOSE(VERSION_PATCH $VERSION_PATCH)
8215
8216 AC_SUBST(VERSION)
8217 AC_SUBST(VERSION_MAJOR)
8218 AC_SUBST(VERSION_MINOR)
8219 AC_SUBST(VERSION_PATCH)
8220
8221 dnl if a package name is given, define its corresponding version info.  We
8222 dnl need the package name to ensure that the defined symbols are unique.
8223 ifelse($1,,,[
8224         cf_PACKAGE=$1
8225         PACKAGE=ifelse($2,,$1,$2)
8226         AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",[Define to the package-name])
8227         AC_SUBST(PACKAGE)
8228         CF_UPPER(cf_PACKAGE,$cf_PACKAGE)
8229         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_VERSION,"${VERSION_MAJOR}.${VERSION_MINOR}")
8230         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_PATCHDATE,${VERSION_PATCH})
8231 ])
8232 ])dnl
8233 dnl ---------------------------------------------------------------------------
8234 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
8235 dnl -------------
8236 dnl Check if type wide-character type $1 is declared, and if so, which header
8237 dnl file is needed.  The second parameter is used to set a shell variable when
8238 dnl the type is not found.  The first parameter sets a shell variable for the
8239 dnl opposite sense.
8240 AC_DEFUN([CF_WCHAR_TYPE],
8241 [
8242 # This is needed on Tru64 5.0 to declare $1
8243 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
8244 AC_TRY_COMPILE([
8245 #include <stdlib.h>
8246 #include <stdarg.h>
8247 #include <stdio.h>
8248 #ifdef HAVE_LIBUTF8_H
8249 #include <libutf8.h>
8250 #endif],
8251         [$1 state],
8252         [cf_cv_$1=no],
8253         [AC_TRY_COMPILE([
8254 #include <stdlib.h>
8255 #include <stdarg.h>
8256 #include <stdio.h>
8257 #include <wchar.h>
8258 #ifdef HAVE_LIBUTF8_H
8259 #include <libutf8.h>
8260 #endif],
8261         [$1 value],
8262         [cf_cv_$1=yes],
8263         [cf_cv_$1=unknown])])])
8264
8265 if test "$cf_cv_$1" = yes ; then
8266         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
8267         NEED_WCHAR_H=1
8268 fi
8269
8270 ifelse([$2],,,[
8271 # if we do not find $1 in either place, use substitution to provide a fallback.
8272 if test "$cf_cv_$1" = unknown ; then
8273         $2=1
8274 fi
8275 ])
8276 ifelse($3,,,[
8277 # if we find $1 in either place, use substitution to provide a fallback.
8278 if test "$cf_cv_$1" != unknown ; then
8279         $3=1
8280 fi
8281 ])
8282 ])dnl
8283 dnl ---------------------------------------------------------------------------
8284 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
8285 dnl ---------------
8286 dnl Check for compiler-support for weak symbols.
8287 dnl This works with "recent" gcc.
8288 AC_DEFUN([CF_WEAK_SYMBOLS],[
8289 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
8290
8291 AC_TRY_COMPILE([
8292 #include <stdio.h>],
8293 [
8294 #if defined(__GNUC__)
8295 #  if defined __USE_ISOC99
8296 #    define _cat_pragma(exp)    _Pragma(#exp)
8297 #    define _weak_pragma(exp)   _cat_pragma(weak name)
8298 #  else
8299 #    define _weak_pragma(exp)
8300 #  endif
8301 #  define _declare(name)        __extension__ extern __typeof__(name) name
8302 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
8303 #endif
8304
8305 weak_symbol(fopen);
8306 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
8307 ])
8308 ])dnl
8309 dnl ---------------------------------------------------------------------------
8310 dnl CF_WITH_ABI_VERSION version: 3 updated: 2015/06/06 16:10:11
8311 dnl -------------------
8312 dnl Allow library's ABI to be overridden.  Generally this happens when a
8313 dnl packager has incremented the ABI past that used in the original package,
8314 dnl and wishes to keep doing this.
8315 dnl
8316 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
8317 dnl symbol.
8318 AC_DEFUN([CF_WITH_ABI_VERSION],[
8319 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
8320 AC_ARG_WITH(abi-version,
8321 [  --with-abi-version=XXX  override derived ABI version],[
8322         if test "x$cf_cv_abi_version" != "x$withval"
8323         then
8324                 AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
8325                 case $cf_cv_rel_version in
8326                 (5.*)
8327                         cf_cv_rel_version=$withval.0
8328                         ;;
8329                 (6.*)
8330                         cf_cv_rel_version=$withval.9    # FIXME: should be 10 as of 6.0 release
8331                         ;;
8332                 esac
8333         fi
8334         cf_cv_abi_version=$withval])
8335         CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
8336 ifelse($1,,,[
8337 $1_ABI=$cf_cv_abi_version
8338 ])
8339 ])dnl
8340 dnl ---------------------------------------------------------------------------
8341 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
8342 dnl --------------------
8343 dnl Command-line option to specify the Ada95 compiler.
8344 AC_DEFUN([CF_WITH_ADA_COMPILER],[
8345 AC_MSG_CHECKING(for ada-compiler)
8346 AC_ARG_WITH(ada-compiler,
8347         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
8348         [cf_ada_compiler=$withval],
8349         [cf_ada_compiler=gnatmake])
8350 AC_SUBST(cf_ada_compiler)
8351 AC_MSG_RESULT($cf_ada_compiler)
8352 ])dnl
8353 dnl ---------------------------------------------------------------------------
8354 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
8355 dnl -------------------
8356 dnl Command-line option to specify where Ada includes will install.
8357 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
8358 AC_MSG_CHECKING(for ada-include)
8359 CF_WITH_PATH(ada-include,
8360    [  --with-ada-include=DIR  Ada includes are in DIR],
8361    ADA_INCLUDE,
8362    PREFIX/share/ada/adainclude,
8363    [$]prefix/share/ada/adainclude)
8364 AC_SUBST(ADA_INCLUDE)
8365 AC_MSG_RESULT($ADA_INCLUDE)
8366 ])dnl
8367 dnl ---------------------------------------------------------------------------
8368 dnl CF_WITH_ADA_LIBNAME version: 1 updated: 2019/09/07 18:59:41
8369 dnl -------------------
8370 dnl CF_WITH_ADA_LIBNAME
8371 dnl -------------------
8372 dnl Command-line option to specify how to name the resulting Ada library.
8373 dnl $1 = default value
8374 AC_DEFUN([CF_WITH_ADA_LIBNAME],[
8375 AC_MSG_CHECKING(for ada-libname)
8376 AC_ARG_WITH(ada-libname,
8377    [  --with-ada-libname=XXX  override default Ada library-name],
8378    ADA_LIBNAME=[$]withval,
8379    ADA_LIBNAME=$1)
8380 case "x$ADA_LIBNAME" in
8381 (x|xyes|xno)
8382         ADA_LIBNAME=$1
8383         ;;
8384 esac
8385 AC_SUBST(ADA_LIBNAME)
8386 AC_MSG_RESULT($ADA_LIBNAME)
8387 ])dnl
8388 dnl ---------------------------------------------------------------------------
8389 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
8390 dnl -------------------
8391 dnl Command-line option to specify where Ada objects will install.
8392 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
8393 AC_MSG_CHECKING(for ada-objects)
8394 CF_WITH_PATH(ada-objects,
8395    [  --with-ada-objects=DIR  Ada objects are in DIR],
8396    ADA_OBJECTS,
8397    PREFIX/lib/ada/adalib,
8398    [$]prefix/lib/ada/adalib)
8399 AC_SUBST(ADA_OBJECTS)
8400 AC_MSG_RESULT($ADA_OBJECTS)
8401 ])dnl
8402 dnl ---------------------------------------------------------------------------
8403 dnl CF_WITH_ADA_SHAREDLIB version: 5 updated: 2018/07/21 19:10:35
8404 dnl ---------------------
8405 dnl Command-line option to specify if an Ada95 shared-library should be built,
8406 dnl and optionally what its soname should be.
8407 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
8408 AC_REQUIRE([CF_GNAT_PROJECTS])
8409 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
8410 AC_ARG_WITH(ada-sharedlib,
8411         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
8412         [with_ada_sharedlib=$withval],
8413         [with_ada_sharedlib=no])
8414 AC_MSG_RESULT($with_ada_sharedlib)
8415
8416 if test "x$with_ada_sharedlib" != xno
8417 then
8418         if test "x$cf_gnat_projects" != xyes
8419         then
8420                 AC_MSG_WARN(disabling shared-library since GNAT projects are not supported)
8421                 with_ada_sharedlib=no
8422         fi
8423 fi
8424
8425 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
8426 MAKE_ADA_SHAREDLIB="#"
8427
8428 if test "x$with_ada_sharedlib" != xno
8429 then
8430         MAKE_ADA_SHAREDLIB=
8431         if test "x$with_ada_sharedlib" != xyes
8432         then
8433                 ADA_SHAREDLIB="$with_ada_sharedlib"
8434         fi
8435 fi
8436
8437 AC_SUBST(ADA_SHAREDLIB)
8438 AC_SUBST(MAKE_ADA_SHAREDLIB)
8439 ])dnl
8440 dnl ---------------------------------------------------------------------------
8441 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
8442 dnl ----------------
8443 dnl Configure-option for dbmalloc.  The optional parameter is used to override
8444 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
8445 AC_DEFUN([CF_WITH_DBMALLOC],[
8446 CF_NO_LEAKS_OPTION(dbmalloc,
8447         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
8448         [USE_DBMALLOC])
8449
8450 if test "$with_dbmalloc" = yes ; then
8451         AC_CHECK_HEADER(dbmalloc.h,
8452                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
8453 fi
8454 ])dnl
8455 dnl ---------------------------------------------------------------------------
8456 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
8457 dnl ---------------
8458 dnl Configure-option for dmalloc.  The optional parameter is used to override
8459 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
8460 AC_DEFUN([CF_WITH_DMALLOC],[
8461 CF_NO_LEAKS_OPTION(dmalloc,
8462         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
8463         [USE_DMALLOC])
8464
8465 if test "$with_dmalloc" = yes ; then
8466         AC_CHECK_HEADER(dmalloc.h,
8467                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
8468 fi
8469 ])dnl
8470 dnl ---------------------------------------------------------------------------
8471 dnl CF_WITH_EXPORT_SYMS version: 3 updated: 2014/12/20 19:16:08
8472 dnl -------------------
8473 dnl Use this with libtool to specify the list of symbols that may be exported.
8474 dnl The input file contains one symbol per line; comments work with "#".
8475 dnl
8476 dnl $1 = basename of the ".sym" file (default $PACKAGE)
8477 AC_DEFUN([CF_WITH_EXPORT_SYMS],
8478 [
8479 AC_MSG_CHECKING(if exported-symbols file should be used)
8480 AC_ARG_WITH(export-syms,
8481         [  --with-export-syms=XXX  limit exported symbols using libtool],
8482         [with_export_syms=$withval],
8483         [with_export_syms=no])
8484 if test "x$with_export_syms" = xyes
8485 then
8486         with_export_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).sym'
8487         AC_SUBST(PACKAGE)
8488 fi
8489 AC_MSG_RESULT($with_export_syms)
8490 if test "x$with_export_syms" != xno
8491 then
8492         EXPORT_SYMS="-export-symbols $with_export_syms"
8493         AC_SUBST(EXPORT_SYMS)
8494 fi
8495 ])dnl
8496 dnl ---------------------------------------------------------------------------
8497 dnl CF_WITH_GPM version: 10 updated: 2017/04/29 18:32:18
8498 dnl -----------
8499 dnl
8500 dnl The option parameter (if neither yes/no) is assumed to be the name of
8501 dnl the gpm library, e.g., for dynamic loading.
8502 AC_DEFUN([CF_WITH_GPM],
8503 [
8504 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
8505 AC_ARG_WITH(gpm,
8506         [  --with-gpm              use Alessandro Rubini's GPM library],
8507         [with_gpm=$withval],
8508         [with_gpm=maybe])
8509 AC_MSG_RESULT($with_gpm)
8510
8511 if test "$with_gpm" != no ; then
8512         AC_CHECK_HEADER(gpm.h,[
8513                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
8514                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
8515                         CF_VERBOSE(assuming we really have GPM library)
8516                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
8517                         with_gpm=yes
8518                 else
8519                         AC_CHECK_LIB(gpm,Gpm_Open,[with_gpm=yes],[
8520                                 if test "$with_gpm" = maybe; then
8521                                         AC_MSG_WARN(Cannot link with GPM library)
8522                                         with_gpm=no
8523                                 else
8524                                         AC_MSG_ERROR(Cannot link with GPM library)
8525                                 fi
8526                         ])
8527                 fi
8528         ],[
8529                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
8530                 with_gpm=no
8531         ])
8532 fi
8533 ])
8534 dnl ---------------------------------------------------------------------------
8535 dnl CF_WITH_LIBTOOL version: 35 updated: 2017/08/12 07:58:51
8536 dnl ---------------
8537 dnl Provide a configure option to incorporate libtool.  Define several useful
8538 dnl symbols for the makefile rules.
8539 dnl
8540 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
8541 dnl macros from libtool.m4 which is in the aclocal directory of automake.
8542 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
8543 dnl But that still does not work properly since the macro is expanded outside
8544 dnl the CF_WITH_LIBTOOL macro:
8545 dnl
8546 dnl     #!/bin/sh
8547 dnl     ACLOCAL=`aclocal --print-ac-dir`
8548 dnl     if test -z "$ACLOCAL" ; then
8549 dnl             echo cannot find aclocal directory
8550 dnl             exit 1
8551 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
8552 dnl             echo cannot find libtool.m4 file
8553 dnl             exit 1
8554 dnl     fi
8555 dnl
8556 dnl     LOCAL=aclocal.m4
8557 dnl     ORIG=aclocal.m4.orig
8558 dnl
8559 dnl     trap "mv $ORIG $LOCAL" 0 1 2 3 15
8560 dnl     rm -f $ORIG
8561 dnl     mv $LOCAL $ORIG
8562 dnl
8563 dnl     # sed the LIBTOOL= assignment to omit the current directory?
8564 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
8565 dnl     cat $ORIG >>$LOCAL
8566 dnl
8567 dnl     autoconf-257 $*
8568 dnl
8569 AC_DEFUN([CF_WITH_LIBTOOL],
8570 [
8571 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
8572 ifdef([AC_PROG_LIBTOOL],,[
8573 LIBTOOL=
8574 ])
8575 # common library maintenance symbols that are convenient for libtool scripts:
8576 LIB_CREATE='${AR} -cr'
8577 LIB_OBJECT='${OBJECTS}'
8578 LIB_SUFFIX=.a
8579 LIB_PREP="$RANLIB"
8580
8581 # symbols used to prop libtool up to enable it to determine what it should be
8582 # doing:
8583 LIB_CLEAN=
8584 LIB_COMPILE=
8585 LIB_LINK='${CC}'
8586 LIB_INSTALL=
8587 LIB_UNINSTALL=
8588
8589 AC_MSG_CHECKING(if you want to build libraries with libtool)
8590 AC_ARG_WITH(libtool,
8591         [  --with-libtool          generate libraries with libtool],
8592         [with_libtool=$withval],
8593         [with_libtool=no])
8594 AC_MSG_RESULT($with_libtool)
8595 if test "$with_libtool" != "no"; then
8596 ifdef([AC_PROG_LIBTOOL],[
8597         # missing_content_AC_PROG_LIBTOOL{{
8598         AC_PROG_LIBTOOL
8599         # missing_content_AC_PROG_LIBTOOL}}
8600 ],[
8601         if test "$with_libtool" != "yes" ; then
8602                 CF_PATH_SYNTAX(with_libtool)
8603                 LIBTOOL=$with_libtool
8604         else
8605                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
8606                 CF_LIBTOOL_VERSION
8607                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
8608                 then
8609                         CF_FORGET_TOOL(LIBTOOL)
8610                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
8611                         CF_LIBTOOL_VERSION
8612                 fi
8613         fi
8614         if test -z "$LIBTOOL" ; then
8615                 AC_MSG_ERROR(Cannot find libtool)
8616         fi
8617 ])dnl
8618         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${libdir} ${LIBTOOL_VERSION} `cut -f1 ${top_srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
8619         LIB_OBJECT='${OBJECTS:.o=.lo}'
8620         LIB_SUFFIX=.la
8621         LIB_CLEAN='${LIBTOOL} --mode=clean'
8622         LIB_COMPILE='${LIBTOOL} --mode=compile'
8623         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
8624         LIB_INSTALL='${LIBTOOL} --mode=install'
8625         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
8626         LIB_PREP=:
8627
8628         CF_CHECK_LIBTOOL_VERSION
8629
8630         # special hack to add -no-undefined (which libtool should do for itself)
8631         LT_UNDEF=
8632         case "$cf_cv_system_name" in
8633         (cygwin*|msys*|mingw32*|os2*|uwin*|aix[[4-7]])
8634                 LT_UNDEF=-no-undefined
8635                 ;;
8636         esac
8637         AC_SUBST([LT_UNDEF])
8638
8639         # special hack to add --tag option for C++ compiler
8640         case $cf_cv_libtool_version in
8641         (1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*)
8642                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
8643                 LIBTOOL="$LIBTOOL --tag=CC"
8644                 ;;
8645         (*)
8646                 LIBTOOL_CXX="$LIBTOOL"
8647                 ;;
8648         esac
8649 else
8650         LIBTOOL=""
8651         LIBTOOL_CXX=""
8652 fi
8653
8654 test -z "$LIBTOOL" && ECHO_LT=
8655
8656 AC_SUBST(LIBTOOL)
8657 AC_SUBST(LIBTOOL_CXX)
8658 AC_SUBST(LIBTOOL_OPTS)
8659
8660 AC_SUBST(LIB_CREATE)
8661 AC_SUBST(LIB_OBJECT)
8662 AC_SUBST(LIB_SUFFIX)
8663 AC_SUBST(LIB_PREP)
8664
8665 AC_SUBST(LIB_CLEAN)
8666 AC_SUBST(LIB_COMPILE)
8667 AC_SUBST(LIB_LINK)
8668 AC_SUBST(LIB_INSTALL)
8669 AC_SUBST(LIB_UNINSTALL)
8670
8671 ])dnl
8672 dnl ---------------------------------------------------------------------------
8673 dnl CF_WITH_LIBTOOL_OPTS version: 4 updated: 2015/04/17 21:13:04
8674 dnl --------------------
8675 dnl Allow user to pass additional libtool options into the library creation
8676 dnl and link steps.  The main use for this is to do something like
8677 dnl     ./configure --with-libtool-opts=-static
8678 dnl to get the same behavior as automake-flavored
8679 dnl     ./configure --enable-static
8680 AC_DEFUN([CF_WITH_LIBTOOL_OPTS],[
8681 AC_MSG_CHECKING(for additional libtool options)
8682 AC_ARG_WITH(libtool-opts,
8683         [  --with-libtool-opts=XXX specify additional libtool options],
8684         [with_libtool_opts=$withval],
8685         [with_libtool_opts=no])
8686 AC_MSG_RESULT($with_libtool_opts)
8687
8688 case .$with_libtool_opts in
8689 (.yes|.no|.)
8690         ;;
8691 (*)
8692         LIBTOOL_OPTS="$LIBTOOL_OPTS $with_libtool_opts"
8693         ;;
8694 esac
8695
8696 AC_SUBST(LIBTOOL_OPTS)
8697 ])dnl
8698 dnl ---------------------------------------------------------------------------
8699 dnl CF_WITH_LIB_BASENAME version: 1 updated: 2020/03/07 20:05:14
8700 dnl --------------------
8701 dnl Allow for overriding the basename of a library, i.e., the part to which
8702 dnl prefixes/suffixes are attached.
8703 dnl
8704 dnl $1 = variable to set
8705 dnl $2 = option name
8706 dnl $3 = default basename for library, if omitted use $2
8707 AC_DEFUN([CF_WITH_LIB_BASENAME],
8708 [
8709 AC_MSG_CHECKING(for desired basename for $2 library)
8710 AC_ARG_WITH($2-libname,
8711         [  --with-$2-libname=XXX override ifelse($3,,$2,$3) basename of library],
8712         [with_lib_basename=$withval],
8713         [with_lib_basename=ifelse($3,,$2,$3)])
8714 $1="$with_lib_basename"
8715
8716 case "x[$]$1" in
8717 (x|xno|xnone|xyes)
8718         $1=ifelse($3,,$2,$3)
8719         ;;
8720 (*)
8721         ;;
8722 esac
8723
8724 AC_MSG_RESULT([$]$1)
8725 AC_SUBST($1)
8726 ])dnl
8727 dnl ---------------------------------------------------------------------------
8728 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
8729 dnl ------------------
8730 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
8731 dnl "lib" prefix, e.g., because it used the dll naming convention.
8732 dnl
8733 dnl $1 = variable to set
8734 AC_DEFUN([CF_WITH_LIB_PREFIX],
8735 [
8736 AC_MSG_CHECKING(if you want to have a library-prefix)
8737 AC_ARG_WITH(lib-prefix,
8738         [  --with-lib-prefix       override library-prefix],
8739         [with_lib_prefix=$withval],
8740         [with_lib_prefix=auto])
8741 AC_MSG_RESULT($with_lib_prefix)
8742
8743 if test $with_lib_prefix = auto
8744 then
8745         CF_LIB_PREFIX($1)
8746 elif test $with_lib_prefix = no
8747 then
8748         LIB_PREFIX=
8749 else
8750         LIB_PREFIX=$with_lib_prefix
8751 fi
8752 ])dnl
8753 dnl ---------------------------------------------------------------------------
8754 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
8755 dnl ------------
8756 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
8757 dnl defaulting to yes/no.
8758 dnl
8759 dnl $1 = option name
8760 dnl $2 = help-text
8761 dnl $3 = environment variable to set
8762 dnl $4 = default value, shown in the help-message, must be a constant
8763 dnl $5 = default value, if it's an expression & cannot be in the help-message
8764 dnl
8765 AC_DEFUN([CF_WITH_PATH],
8766 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
8767 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
8768 if ifelse([$5],,true,[test -n "$5"]) ; then
8769 CF_PATH_SYNTAX(withval)
8770 fi
8771 eval $3="$withval"
8772 AC_SUBST($3)dnl
8773 ])dnl
8774 dnl ---------------------------------------------------------------------------
8775 dnl CF_WITH_PATHLIST version: 10 updated: 2015/04/17 21:13:04
8776 dnl ----------------
8777 dnl Process an option specifying a list of colon-separated paths.
8778 dnl
8779 dnl $1 = option name
8780 dnl $2 = help-text
8781 dnl $3 = environment variable to set
8782 dnl $4 = default value, shown in the help-message, must be a constant
8783 dnl $5 = default value, if it's an expression & cannot be in the help-message
8784 dnl $6 = flag to tell if we want to define or substitute
8785 dnl
8786 AC_DEFUN([CF_WITH_PATHLIST],[
8787 AC_REQUIRE([CF_PATHSEP])
8788 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
8789 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
8790
8791 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
8792 cf_dst_path=
8793 for cf_src_path in $withval
8794 do
8795   CF_PATH_SYNTAX(cf_src_path)
8796   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
8797   cf_dst_path="${cf_dst_path}${cf_src_path}"
8798 done
8799 IFS="$ac_save_ifs"
8800
8801 ifelse($6,define,[
8802 # Strip single quotes from the value, e.g., when it was supplied as a literal
8803 # for $4 or $5.
8804 case $cf_dst_path in
8805 (\'*)
8806   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
8807   ;;
8808 esac
8809 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
8810 ])
8811
8812 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
8813 # so we have to check/work around.  We do prefer the result of "eval"...
8814 eval cf_dst_eval="$cf_dst_path"
8815 case "x$cf_dst_eval" in
8816 (xNONE*)
8817         $3=$cf_dst_path
8818         ;;
8819 (*)
8820         $3="$cf_dst_eval"
8821         ;;
8822 esac
8823 AC_SUBST($3)dnl
8824
8825 ])dnl
8826 dnl ---------------------------------------------------------------------------
8827 dnl CF_WITH_PATH_PROG version: 1 updated: 2019/06/30 19:44:43
8828 dnl -----------------
8829 dnl Check for a given program, like CF_PATH_PROG, but allow override using a
8830 dnl "--with-xxx" option.
8831 dnl
8832 dnl Parameters:
8833 dnl             $1 = environment variable to set/update
8834 dnl             $2 = program name
8835 dnl             $3 = help-text
8836 dnl             $4 = $PATH
8837 AC_DEFUN([CF_WITH_PATH_PROG],[
8838 AC_ARG_WITH($2-path,
8839         [  --with-$2-path=XXX     specify path of $2 ifelse($3,,,$3)],
8840         [AC_MSG_CHECKING(for $2 program ifelse($3,,,$3))
8841                 $1=$withval
8842                 AC_MSG_RESULT([$]$1)
8843                 CF_PATH_SYNTAX($1)
8844         ],
8845         [CF_PATH_PROG($1,$2,,ifelse($4,,,$4))
8846                 if test -z "[$]$1"
8847                 then
8848                         AC_MSG_WARN(no $2 program found ifelse($3,,,$3))
8849                 fi
8850         ])
8851 ])
8852 dnl ---------------------------------------------------------------------------
8853 dnl CF_WITH_PCRE2 version: 3 updated: 2020/02/29 16:09:19
8854 dnl -------------
8855 dnl Add PCRE2 (Perl-compatible regular expressions v2) to the build if it is
8856 dnl available and the user requests it.  Assume the application will otherwise
8857 dnl use the POSIX interface.
8858 dnl
8859 dnl TODO allow $withval to specify package location
8860 AC_DEFUN([CF_WITH_PCRE2],
8861 [
8862 AC_REQUIRE([CF_PKG_CONFIG])
8863
8864 AC_MSG_CHECKING(if you want to use PCRE2 for regular-expressions)
8865 AC_ARG_WITH(pcre2,
8866         [  --with-pcre2            use PCRE2 for regular-expressions])
8867 test -z "$with_pcre2" && with_pcre2=no
8868 AC_MSG_RESULT($with_pcre2)
8869
8870 if test "x$with_pcre2" != xno ; then
8871         CF_TRY_PKG_CONFIG(libpcre2,,[
8872         CF_TRY_PKG_CONFIG(libpcre,,[
8873                         AC_MSG_ERROR(Cannot find PCRE2 library)])])
8874
8875         AC_DEFINE(HAVE_LIB_PCRE2,1,[Define to 1 if we can/should compile with the PCRE2 library])
8876
8877         # if pkgconfig gave no results, look for the libraries directly
8878         case $LIBS in
8879         (*pcre2-posix*|*pcreposix*)
8880                 ;;
8881         (*)
8882                 AC_CHECK_LIB(pcre2-posix,regcomp,[
8883                         CF_ADD_LIB(pcre2-posix)],
8884                         [AC_CHECK_LIB(pcreposix,regcomp,[
8885                          CF_ADD_LIB(pcreposix)
8886                         ],[AC_MSG_ERROR(Cannot find PCRE2 POSIX library)])])
8887                 ;;
8888         esac
8889
8890         # either way, check for the library header files
8891         AC_CHECK_HEADERS(pcre2posix.h pcreposix.h)
8892 fi
8893 ])dnl
8894 dnl ---------------------------------------------------------------------------
8895 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 10 updated: 2015/08/22 17:10:56
8896 dnl -------------------------
8897 dnl Allow the choice of the pkg-config library directory to be overridden.
8898 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
8899
8900 case $PKG_CONFIG in
8901 (no|none|yes)
8902         AC_MSG_CHECKING(for pkg-config library directory)
8903         ;;
8904 (*)
8905         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
8906         ;;
8907 esac
8908
8909 PKG_CONFIG_LIBDIR=no
8910 AC_ARG_WITH(pkg-config-libdir,
8911         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
8912         [PKG_CONFIG_LIBDIR=$withval],
8913         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
8914
8915 case x$PKG_CONFIG_LIBDIR in
8916 (x/*)
8917         ;;
8918 (xyes)
8919         # Look for the library directory using the same prefix as the executable
8920         if test "x$PKG_CONFIG" = xnone
8921         then
8922                 cf_path=$prefix
8923         else
8924                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
8925         fi
8926
8927         # If you don't like using the default architecture, you have to specify the
8928         # intended library directory and corresponding compiler/linker options.
8929         #
8930         # This case allows for Debian's 2014-flavor of multiarch, along with the
8931         # most common variations before that point.  Some other variants spell the
8932         # directory differently, e.g., "pkg-config", and put it in unusual places.
8933         # pkg-config has always been poorly standardized, which is ironic...
8934         case x`(arch) 2>/dev/null` in
8935         (*64)
8936                 cf_search_path="\
8937                         $cf_path/lib/*64-linux-gnu \
8938                         $cf_path/share \
8939                         $cf_path/lib64 \
8940                         $cf_path/lib32 \
8941                         $cf_path/lib"
8942                 ;;
8943         (*)
8944                 cf_search_path="\
8945                         $cf_path/lib/*-linux-gnu \
8946                         $cf_path/share \
8947                         $cf_path/lib32 \
8948                         $cf_path/lib \
8949                         $cf_path/libdata"
8950                 ;;
8951         esac
8952
8953         CF_VERBOSE(list...)
8954         for cf_config in $cf_search_path
8955         do
8956                 CF_VERBOSE(checking $cf_config/pkgconfig)
8957                 if test -d $cf_config/pkgconfig
8958                 then
8959                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
8960                         AC_MSG_CHECKING(done)
8961                         break
8962                 fi
8963         done
8964         ;;
8965 (*)
8966         ;;
8967 esac
8968
8969 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
8970         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
8971 fi
8972
8973 AC_SUBST(PKG_CONFIG_LIBDIR)
8974 ])dnl
8975 dnl ---------------------------------------------------------------------------
8976 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
8977 dnl ---------------
8978 dnl Check for POSIX thread library.
8979 AC_DEFUN([CF_WITH_PTHREAD],
8980 [
8981 AC_MSG_CHECKING(if you want to link with the pthread library)
8982 AC_ARG_WITH(pthread,
8983         [  --with-pthread          use POSIX thread library],
8984         [with_pthread=$withval],
8985         [with_pthread=no])
8986 AC_MSG_RESULT($with_pthread)
8987
8988 if test "$with_pthread" != no ; then
8989         AC_CHECK_HEADER(pthread.h,[
8990         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
8991
8992         for cf_lib_pthread in pthread c_r
8993         do
8994             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
8995             cf_save_LIBS="$LIBS"
8996             CF_ADD_LIB($cf_lib_pthread)
8997             AC_TRY_LINK([
8998 #include <pthread.h>
8999 ],[
9000                 int rc = pthread_create(0,0,0,0);
9001                 int r2 = pthread_mutexattr_settype(0, 0);
9002 ],[with_pthread=yes],[with_pthread=no])
9003             LIBS="$cf_save_LIBS"
9004             AC_MSG_RESULT($with_pthread)
9005             test "$with_pthread" = yes && break
9006         done
9007
9008         if test "$with_pthread" = yes ; then
9009             CF_ADD_LIB($cf_lib_pthread)
9010             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
9011         else
9012             AC_MSG_ERROR(Cannot link with pthread library)
9013         fi
9014         ])
9015 fi
9016 ])
9017 dnl ---------------------------------------------------------------------------
9018 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
9019 dnl -------------------
9020 dnl Allow library's release-version to be overridden.  Generally this happens when a
9021 dnl packager has incremented the release-version past that used in the original package,
9022 dnl and wishes to keep doing this.
9023 dnl
9024 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
9025 dnl and {package}_MINOR symbols
9026 dnl symbol.
9027 AC_DEFUN([CF_WITH_REL_VERSION],[
9028 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
9029 AC_ARG_WITH(rel-version,
9030 [  --with-rel-version=XXX  override derived release version],
9031 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
9032  cf_cv_rel_version=$withval])
9033 ifelse($1,,[
9034  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
9035 ],[
9036  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
9037  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
9038  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
9039  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
9040 ])
9041 ])dnl
9042 dnl ---------------------------------------------------------------------------
9043 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
9044 dnl ----------------
9045 dnl If we can compile with sysmouse, make it available unless it is not wanted.
9046 AC_DEFUN([CF_WITH_SYSMOUSE],[
9047 # not everyone has "test -c"
9048 if test -c /dev/sysmouse 2>/dev/null ; then
9049 AC_MSG_CHECKING(if you want to use sysmouse)
9050 AC_ARG_WITH(sysmouse,
9051         [  --with-sysmouse         use sysmouse (FreeBSD console)],
9052         [cf_with_sysmouse=$withval],
9053         [cf_with_sysmouse=maybe])
9054         if test "$cf_with_sysmouse" != no ; then
9055         AC_TRY_COMPILE([
9056 #include <osreldate.h>
9057 #if (__FreeBSD_version >= 400017)
9058 #include <sys/consio.h>
9059 #include <sys/fbio.h>
9060 #else
9061 #include <machine/console.h>
9062 #endif
9063 ],[
9064         struct mouse_info the_mouse;
9065         ioctl(0, CONS_MOUSECTL, &the_mouse);
9066 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
9067         fi
9068 AC_MSG_RESULT($cf_with_sysmouse)
9069 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
9070 fi
9071 ])dnl
9072 dnl ---------------------------------------------------------------------------
9073 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
9074 dnl ---------------
9075 dnl For testing, override the derived host system-type which is used to decide
9076 dnl things such as the linker commands used to build shared libraries.  This is
9077 dnl normally chosen automatically based on the type of system which you are
9078 dnl building on.  We use it for testing the configure script.
9079 dnl
9080 dnl This is different from the --host option: it is used only for testing parts
9081 dnl of the configure script which would not be reachable with --host since that
9082 dnl relies on the build environment being real, rather than mocked up.
9083 AC_DEFUN([CF_WITH_SYSTYPE],[
9084 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
9085 AC_ARG_WITH(system-type,
9086         [  --with-system-type=XXX  test: override derived host system-type],
9087 [AC_MSG_WARN(overriding system type to $withval)
9088         cf_cv_system_name=$withval
9089         host_os=$withval
9090 ])
9091 ])dnl
9092 dnl ---------------------------------------------------------------------------
9093 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
9094 dnl ----------------
9095 AC_DEFUN([CF_WITH_VALGRIND],[
9096 CF_NO_LEAKS_OPTION(valgrind,
9097         [  --with-valgrind         test: use valgrind],
9098         [USE_VALGRIND])
9099 ])dnl
9100 dnl ---------------------------------------------------------------------------
9101 dnl CF_WITH_VERSIONED_SYMS version: 8 updated: 2018/10/20 20:24:34
9102 dnl ----------------------
9103 dnl Use this when building shared library with ELF, to markup symbols with the
9104 dnl version identifier from the given input file.  Generally that identifier is
9105 dnl the same as the SONAME at which the symbol was first introduced.
9106 dnl
9107 dnl $1 = basename of the ".map" file (default $PACKAGE)
9108 AC_DEFUN([CF_WITH_VERSIONED_SYMS],
9109 [
9110 AC_MSG_CHECKING(if versioned-symbols file should be used)
9111 AC_ARG_WITH(versioned-syms,
9112         [  --with-versioned-syms=X markup versioned symbols using ld],
9113         [with_versioned_syms=$withval],
9114         [with_versioned_syms=no])
9115 case "x$with_versioned_syms" in
9116 (xyes)
9117         with_versioned_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).map'
9118         AC_SUBST(PACKAGE)
9119         ;;
9120 (xno)
9121         ;;
9122 (x/*)
9123         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
9124         ;;
9125 (*)
9126         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
9127         with_versioned_syms=`pwd`/"$with_versioned_syms"
9128         ;;
9129 esac
9130 AC_MSG_RESULT($with_versioned_syms)
9131
9132 RESULTING_SYMS=
9133 VERSIONED_SYMS=
9134 WILDCARD_SYMS=
9135
9136 if test "x$with_versioned_syms" != xno
9137 then
9138         RESULTING_SYMS=$with_versioned_syms
9139         case "x$MK_SHARED_LIB" in
9140         (*-Wl,*)
9141                 VERSIONED_SYMS="-Wl,--version-script,\${RESULTING_SYMS}"
9142                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-Wl,%\\[$]{VERSIONED_SYMS} -Wl,%"`
9143                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
9144                 ;;
9145         (*-dy\ *)
9146                 VERSIONED_SYMS="-Wl,-M,\${RESULTING_SYMS}"
9147                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-dy%\\[$]{VERSIONED_SYMS} -dy%"`
9148                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
9149                 ;;
9150         (*)
9151                 AC_MSG_WARN(this system does not support versioned-symbols)
9152                 ;;
9153         esac
9154
9155         # Linux ld can selectively override scope, e.g., of symbols beginning with
9156         # "_" by first declaring some as global, and then using a wildcard to
9157         # declare the others as local.  Some other loaders cannot do this.  Check
9158         # by constructing a (very) simple shared library and inspecting its
9159         # symbols.
9160         if test "x$VERSIONED_SYMS" != "x"
9161         then
9162                 AC_MSG_CHECKING(if wildcards can be used to selectively omit symbols)
9163                 WILDCARD_SYMS=no
9164
9165                 # make sources
9166                 rm -f conftest.*
9167
9168                 cat >conftest.ver <<EOF
9169 module_1.0 {
9170 global:
9171         globalf1;
9172 local:
9173         localf1;
9174 };
9175 module_2.0 {
9176 global:
9177         globalf2;
9178 local:
9179         localf2;
9180         _*;
9181 } module_1.0;
9182 submodule_1.0 {
9183 global:
9184         subglobalf1;
9185         _ismissing;
9186 local:
9187         sublocalf1;
9188 };
9189 submodule_2.0 {
9190 global:
9191         subglobalf2;
9192 local:
9193         sublocalf2;
9194         _*;
9195 } submodule_1.0;
9196 EOF
9197                 cat >conftest.$ac_ext <<EOF
9198 #line __oline__ "configure"
9199 int     _ismissing(void) { return 1; }
9200 int     _localf1(void) { return 1; }
9201 int     _localf2(void) { return 2; }
9202 int     globalf1(void) { return 1; }
9203 int     globalf2(void) { return 2; }
9204 int     _sublocalf1(void) { return 1; }
9205 int     _sublocalf2(void) { return 2; }
9206 int     subglobalf1(void) { return 1; }
9207 int     subglobalf2(void) { return 2; }
9208 EOF
9209                 cat >conftest.mk <<EOF
9210 CC=${CC}
9211 CFLAGS=${CFLAGS}
9212 CPPFLAGS=${CPPFLAGS}
9213 LDFLAGS=${LDFLAGS}
9214 LIBS=${LIBS}
9215 VERSIONED_SYMS=${VERSIONED_SYMS}
9216 RESULTING_SYMS=conftest.ver
9217 MK_SHARED_LIB=${MK_SHARED_LIB}
9218 conftest.so: conftest.$ac_cv_objext
9219                 \$(MK_SHARED_LIB) conftest.$ac_cv_objext
9220 EOF
9221
9222                 # compile source, make library
9223                 if make -f conftest.mk 2>&AC_FD_CC >/dev/null
9224                 then
9225                         # test for missing symbol in either Data or Text section
9226                         cf_missing=`nm -P conftest.so 2>&AC_FD_CC |fgrep _ismissing | egrep '[[         ]][[DT]][[      ]]'`
9227                         test -n "$cf_missing" && WILDCARD_SYMS=yes
9228                 fi
9229                 AC_MSG_RESULT($WILDCARD_SYMS)
9230                 rm -f conftest.*
9231         fi
9232 fi
9233 AC_SUBST(RESULTING_SYMS)
9234 AC_SUBST(VERSIONED_SYMS)
9235 AC_SUBST(WILDCARD_SYMS)
9236 ])dnl
9237 dnl ---------------------------------------------------------------------------
9238 dnl CF_WITH_X11_RGB version: 2 updated: 2019/12/31 08:53:54
9239 dnl ---------------
9240 dnl Handle configure option "--with-x11-rgb", setting these shell
9241 dnl variables:
9242 dnl
9243 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
9244 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
9245 dnl
9246 dnl Most Linux's use this:
9247 dnl     /usr/share/X11/rgb.txt
9248 dnl Debian uses this:
9249 dnl     /etc/X11/rgb.txt
9250 dnl DragonFlyBSD ports uses this:
9251 dnl     /usr/pkg/lib/X11/rgb.txt
9252 dnl FreeBSD ports use these:
9253 dnl     /usr/local/lib/X11/rgb.txt
9254 dnl     /usr/local/share/X11/rgb.txt
9255 dnl Mandriva has these:
9256 dnl     /usr/lib/X11/rgb.txt
9257 dnl     /usr/lib64/X11/rgb.txt
9258 dnl NetBSD has these
9259 dnl     /usr/X11R7/lib/X11/rgb.txt
9260 dnl OpenSolaris uses
9261 dnl     32-bit:
9262 dnl     /usr/X11/etc/X11/rgb.txt
9263 dnl     /usr/X11/share/X11/rgb.txt
9264 dnl     /usr/X11/lib/X11/rgb.txt
9265 dnl OSX uses
9266 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
9267 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
9268 dnl     64-bit:
9269 dnl     /usr/X11/etc/X11/rgb.txt
9270 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
9271 dnl     /usr/X11/lib/amd64/X11/rgb.txt
9272 dnl Solaris10 uses (in this order):
9273 dnl     /usr/openwin/lib/X11/rgb.txt
9274 dnl     /usr/X11/lib/X11/rgb.txt
9275 AC_DEFUN([CF_WITH_X11_RGB],[
9276 AC_MSG_CHECKING(for X11 rgb file)
9277 AC_ARG_WITH(x11-rgb,
9278         [  --with-x11-rgb=FILE   file containing X11 rgb information (EPREFIX/lib/X11/rgb.txt)],
9279         [RGB_PATH=$withval],
9280         [RGB_PATH=auto])
9281
9282 if test "x[$]RGB_PATH" = xauto
9283 then
9284         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
9285         for cf_path in \
9286                 /opt/local/share/X11/rgb.txt \
9287                 /opt/X11/share/X11/rgb.txt \
9288                 /usr/share/X11/rgb.txt \
9289                 /usr/X11/share/X11/rgb.txt \
9290                 /usr/X11/lib/X11/rgb.txt \
9291                 /usr/lib/X11/rgb.txt \
9292                 /etc/X11/rgb.txt \
9293                 /usr/pkg/lib/X11/rgb.txt \
9294                 /usr/X11R7/lib/X11/rgb.txt \
9295                 /usr/X11R6/lib/X11/rgb.txt \
9296                 /usr/X11R5/lib/X11/rgb.txt \
9297                 /usr/X11R4/lib/X11/rgb.txt \
9298                 /usr/local/lib/X11/rgb.txt \
9299                 /usr/local/share/X11/rgb.txt \
9300                 /usr/lib64/X11/rgb.txt
9301         do
9302                 if test -f "$cf_path" ; then
9303                         RGB_PATH="$cf_path"
9304                         break
9305                 fi
9306         done
9307 else
9308         cf_path=$RGB_PATH
9309         CF_PATH_SYNTAX(cf_path)
9310 fi
9311
9312 AC_MSG_RESULT($RGB_PATH)
9313 AC_SUBST(RGB_PATH)
9314 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path",[Define to the full pathname of rgb.txt])
9315
9316 no_x11_rgb=
9317 if test "$RGB_PATH" = no
9318 then
9319         no_x11_rgb="#"
9320 fi
9321 AC_SUBST(no_x11_rgb)
9322 ])dnl
9323 dnl ---------------------------------------------------------------------------
9324 dnl CF_XOPEN_SOURCE version: 55 updated: 2018/12/31 20:46:17
9325 dnl ---------------
9326 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
9327 dnl or adapt to the vendor's definitions to get equivalent functionality,
9328 dnl without losing the common non-POSIX features.
9329 dnl
9330 dnl Parameters:
9331 dnl     $1 is the nominal value for _XOPEN_SOURCE
9332 dnl     $2 is the nominal value for _POSIX_C_SOURCE
9333 AC_DEFUN([CF_XOPEN_SOURCE],[
9334 AC_REQUIRE([AC_CANONICAL_HOST])
9335 AC_REQUIRE([CF_POSIX_VISIBLE])
9336
9337 if test "$cf_cv_posix_visible" = no; then
9338
9339 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
9340 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
9341 cf_xopen_source=
9342
9343 case $host_os in
9344 (aix[[4-7]]*)
9345         cf_xopen_source="-D_ALL_SOURCE"
9346         ;;
9347 (msys)
9348         cf_XOPEN_SOURCE=600
9349         ;;
9350 (darwin[[0-8]].*)
9351         cf_xopen_source="-D_APPLE_C_SOURCE"
9352         ;;
9353 (darwin*)
9354         cf_xopen_source="-D_DARWIN_C_SOURCE"
9355         cf_XOPEN_SOURCE=
9356         ;;
9357 (freebsd*|dragonfly*|midnightbsd*)
9358         # 5.x headers associate
9359         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
9360         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
9361         cf_POSIX_C_SOURCE=200112L
9362         cf_XOPEN_SOURCE=600
9363         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
9364         ;;
9365 (hpux11*)
9366         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
9367         ;;
9368 (hpux*)
9369         cf_xopen_source="-D_HPUX_SOURCE"
9370         ;;
9371 (irix[[56]].*)
9372         cf_xopen_source="-D_SGI_SOURCE"
9373         cf_XOPEN_SOURCE=
9374         ;;
9375 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
9376         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
9377         ;;
9378 (minix*)
9379         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
9380         ;;
9381 (mirbsd*)
9382         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
9383         cf_XOPEN_SOURCE=
9384         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
9385         ;;
9386 (netbsd*)
9387         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
9388         ;;
9389 (openbsd[[4-9]]*)
9390         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
9391         cf_xopen_source="-D_BSD_SOURCE"
9392         cf_XOPEN_SOURCE=600
9393         ;;
9394 (openbsd*)
9395         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
9396         ;;
9397 (osf[[45]]*)
9398         cf_xopen_source="-D_OSF_SOURCE"
9399         ;;
9400 (nto-qnx*)
9401         cf_xopen_source="-D_QNX_SOURCE"
9402         ;;
9403 (sco*)
9404         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
9405         ;;
9406 (solaris2.*)
9407         cf_xopen_source="-D__EXTENSIONS__"
9408         cf_cv_xopen_source=broken
9409         ;;
9410 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
9411         cf_XOPEN_SOURCE=
9412         cf_POSIX_C_SOURCE=
9413         ;;
9414 (*)
9415         CF_TRY_XOPEN_SOURCE
9416         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
9417         ;;
9418 esac
9419
9420 if test -n "$cf_xopen_source" ; then
9421         CF_ADD_CFLAGS($cf_xopen_source,true)
9422 fi
9423
9424 dnl In anything but the default case, we may have system-specific setting
9425 dnl which is still not guaranteed to provide all of the entrypoints that
9426 dnl _XOPEN_SOURCE would yield.
9427 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
9428         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
9429         AC_TRY_COMPILE([#include <stdlib.h>],[
9430 #ifndef _XOPEN_SOURCE
9431 make an error
9432 #endif],
9433         [cf_XOPEN_SOURCE_set=yes],
9434         [cf_XOPEN_SOURCE_set=no])
9435         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
9436         if test $cf_XOPEN_SOURCE_set = yes
9437         then
9438                 AC_TRY_COMPILE([#include <stdlib.h>],[
9439 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
9440 make an error
9441 #endif],
9442                 [cf_XOPEN_SOURCE_set_ok=yes],
9443                 [cf_XOPEN_SOURCE_set_ok=no])
9444                 if test $cf_XOPEN_SOURCE_set_ok = no
9445                 then
9446                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
9447                 fi
9448         else
9449                 CF_TRY_XOPEN_SOURCE
9450         fi
9451 fi
9452 fi # cf_cv_posix_visible
9453 ])