aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2015,2016 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.800 2016/09/10 19:33:21 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54         [AC_TRY_LINK([#include <langinfo.h>],
  55         [char* cs = nl_langinfo(CODESET);],
  56         am_cv_langinfo_codeset=yes,
  57         am_cv_langinfo_codeset=no)
  58         ])
  59         if test $am_cv_langinfo_codeset = yes; then
  60                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62         fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
  66 dnl ---------------
  67 dnl Provide configure-script defaults for different ncurses ABIs.
  68 AC_DEFUN([CF_ABI_DEFAULTS],[
  69 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  70 case x$cf_cv_abi_version in
  71 (x[[6789]])
  72         cf_dft_ext_colors=yes
  73         cf_dft_ext_const=yes
  74         cf_dft_ext_mouse=yes
  75         cf_dft_ext_putwin=yes
  76         cf_dft_ext_spfuncs=yes
  77         cf_dft_filter_syms=yes
  78         cf_dft_chtype=uint32_t
  79         cf_dft_mmask_t=uint32_t
  80         cf_dft_interop=yes
  81         cf_dft_tparm_arg=intptr_t
  82         cf_dft_with_lp64=yes
  83         ;;
  84 (*)
  85         cf_dft_ext_colors=no
  86         cf_dft_ext_const=no
  87         cf_dft_ext_mouse=no
  88         cf_dft_ext_putwin=no
  89         cf_dft_ext_spfuncs=no
  90         cf_dft_filter_syms=no
  91         cf_dft_chtype=auto
  92         cf_dft_mmask_t=auto
  93         cf_dft_interop=no
  94         cf_dft_tparm_arg=long
  95         cf_dft_with_lp64=no
  96         ;;
  97 esac
  98 ])dnl
  99 dnl ---------------------------------------------------------------------------
 100 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 101 dnl ------------------
 102 dnl Conditionally generate script according to whether we're using a given autoconf.
 103 dnl
 104 dnl $1 = version to compare against
 105 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 106 dnl $3 = code to use if AC_ACVERSION is older than $1.
 107 define([CF_ACVERSION_CHECK],
 108 [
 109 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 110 ifdef([m4_version_compare],
 111 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 112 [CF_ACVERSION_COMPARE(
 113 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 114 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 115 dnl ---------------------------------------------------------------------------
 116 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 117 dnl --------------------
 118 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 119 dnl                      MAJOR2, MINOR2, TERNARY2,
 120 dnl                      PRINTABLE2, not FOUND, FOUND)
 121 define([CF_ACVERSION_COMPARE],
 122 [ifelse(builtin([eval], [$2 < $5]), 1,
 123 [ifelse([$8], , ,[$8])],
 124 [ifelse([$9], , ,[$9])])])dnl
 125 dnl ---------------------------------------------------------------------------
 126 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 127 dnl -------------------
 128 dnl Construct the list of include-options for the C programs in the Ada95
 129 dnl binding.
 130 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 131 [
 132 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 133 if test "$srcdir" != "."; then
 134         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 135 fi
 136 if test "$GCC" != yes; then
 137         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 138 elif test "$includedir" != "/usr/include"; then
 139         if test "$includedir" = '${prefix}/include' ; then
 140                 if test x$prefix != x/usr ; then
 141                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 142                 fi
 143         else
 144                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 145         fi
 146 fi
 147 AC_SUBST(ACPPFLAGS)
 148 ])dnl
 149 dnl ---------------------------------------------------------------------------
 150 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 151 dnl ---------------
 152 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 153 AC_DEFUN([CF_ADD_ADAFLAGS],[
 154         ADAFLAGS="$ADAFLAGS $1"
 155         AC_SUBST(ADAFLAGS)
 156 ])dnl
 157 dnl ---------------------------------------------------------------------------
 158 dnl CF_ADD_CFLAGS version: 12 updated: 2015/04/12 15:39:00
 159 dnl -------------
 160 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 161 dnl The second parameter if given makes this macro verbose.
 162 dnl
 163 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 164 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 165 dnl confused by the quotes (which require backslashes to keep them usable).
 166 AC_DEFUN([CF_ADD_CFLAGS],
 167 [
 168 cf_fix_cppflags=no
 169 cf_new_cflags=
 170 cf_new_cppflags=
 171 cf_new_extra_cppflags=
 172
 173 for cf_add_cflags in $1
 174 do
 175 case $cf_fix_cppflags in
 176 (no)
 177         case $cf_add_cflags in
 178         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 179                 case $cf_add_cflags in
 180                 (-D*)
 181                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 182
 183                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 184                                 && test -z "${cf_tst_cflags}" \
 185                                 && cf_fix_cppflags=yes
 186
 187                         if test $cf_fix_cppflags = yes ; then
 188                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 189                                 continue
 190                         elif test "${cf_tst_cflags}" = "\"'" ; then
 191                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 192                                 continue
 193                         fi
 194                         ;;
 195                 esac
 196                 case "$CPPFLAGS" in
 197                 (*$cf_add_cflags)
 198                         ;;
 199                 (*)
 200                         case $cf_add_cflags in
 201                         (-D*)
 202                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 203                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 204                                 ;;
 205                         esac
 206                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 207                         ;;
 208                 esac
 209                 ;;
 210         (*)
 211                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 212                 ;;
 213         esac
 214         ;;
 215 (yes)
 216         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 217
 218         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 219
 220         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 221                 && test -z "${cf_tst_cflags}" \
 222                 && cf_fix_cppflags=no
 223         ;;
 224 esac
 225 done
 226
 227 if test -n "$cf_new_cflags" ; then
 228         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 229         CFLAGS="$CFLAGS $cf_new_cflags"
 230 fi
 231
 232 if test -n "$cf_new_cppflags" ; then
 233         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 234         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 235 fi
 236
 237 if test -n "$cf_new_extra_cppflags" ; then
 238         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 239         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 240 fi
 241
 242 AC_SUBST(EXTRA_CPPFLAGS)
 243
 244 ])dnl
 245 dnl ---------------------------------------------------------------------------
 246 dnl CF_ADD_INCDIR version: 14 updated: 2015/05/25 20:53:04
 247 dnl -------------
 248 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 249 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 250 dnl but old versions (and some misinstalled ones) need that.  To make things
 251 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 252 dnl the include-path).
 253 AC_DEFUN([CF_ADD_INCDIR],
 254 [
 255 if test -n "$1" ; then
 256   for cf_add_incdir in $1
 257   do
 258         while test $cf_add_incdir != /usr/include
 259         do
 260           if test -d $cf_add_incdir
 261           then
 262                 cf_have_incdir=no
 263                 if test -n "$CFLAGS$CPPFLAGS" ; then
 264                   # a loop is needed to ensure we can add subdirs of existing dirs
 265                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 266                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 267                           cf_have_incdir=yes; break
 268                         fi
 269                   done
 270                 fi
 271
 272                 if test "$cf_have_incdir" = no ; then
 273                   if test "$cf_add_incdir" = /usr/local/include ; then
 274                         if test "$GCC" = yes
 275                         then
 276                           cf_save_CPPFLAGS=$CPPFLAGS
 277                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 278                           AC_TRY_COMPILE([#include <stdio.h>],
 279                                   [printf("Hello")],
 280                                   [],
 281                                   [cf_have_incdir=yes])
 282                           CPPFLAGS=$cf_save_CPPFLAGS
 283                         fi
 284                   fi
 285                 fi
 286
 287                 if test "$cf_have_incdir" = no ; then
 288                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 289                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 290
 291                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 292                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 293                   cf_add_incdir="$cf_top_incdir"
 294                 else
 295                   break
 296                 fi
 297           else
 298                 break
 299           fi
 300         done
 301   done
 302 fi
 303 ])dnl
 304 dnl ---------------------------------------------------------------------------
 305 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 306 dnl ----------
 307 dnl Add a library, used to enforce consistency.
 308 dnl
 309 dnl $1 = library to add, without the "-l"
 310 dnl $2 = variable to update (default $LIBS)
 311 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 312 dnl ---------------------------------------------------------------------------
 313 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 314 dnl -------------
 315 dnl     Adds to the library-path
 316 dnl
 317 dnl     Some machines have trouble with multiple -L options.
 318 dnl
 319 dnl $1 is the (list of) directory(s) to add
 320 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 321 dnl
 322 AC_DEFUN([CF_ADD_LIBDIR],
 323 [
 324 if test -n "$1" ; then
 325         for cf_add_libdir in $1
 326         do
 327                 if test $cf_add_libdir = /usr/lib ; then
 328                         :
 329                 elif test -d $cf_add_libdir
 330                 then
 331                         cf_have_libdir=no
 332                         if test -n "$LDFLAGS$LIBS" ; then
 333                                 # a loop is needed to ensure we can add subdirs of existing dirs
 334                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 335                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 336                                                 cf_have_libdir=yes; break
 337                                         fi
 338                                 done
 339                         fi
 340                         if test "$cf_have_libdir" = no ; then
 341                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 342                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 343                         fi
 344                 fi
 345         done
 346 fi
 347 ])dnl
 348 dnl ---------------------------------------------------------------------------
 349 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 350 dnl -----------
 351 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 352 dnl prepended to an existing list, since their dependencies are assumed to
 353 dnl already exist in the list.
 354 dnl
 355 dnl $1 = libraries to add, with the "-l", etc.
 356 dnl $2 = variable to update (default $LIBS)
 357 AC_DEFUN([CF_ADD_LIBS],[
 358 cf_add_libs="$1"
 359 # Filter out duplicates - this happens with badly-designed ".pc" files...
 360 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 361 do
 362         for cf_add_2lib in $cf_add_libs
 363         do
 364                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 365                 then
 366                         cf_add_1lib=
 367                         break
 368                 fi
 369         done
 370         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 371 done
 372 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 373 ])dnl
 374 dnl ---------------------------------------------------------------------------
 375 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 376 dnl ------------------
 377 dnl Append to a search-list for a nonstandard header/lib-file
 378 dnl     $1 = the variable to return as result
 379 dnl     $2 = the package name
 380 dnl     $3 = the subdirectory, e.g., bin, include or lib
 381 dnl $4 = the directory under which we will test for subdirectories
 382 dnl $5 = a directory that we do not want $4 to match
 383 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 384 [
 385 test "x$4" != "x$5" && \
 386 test -d "$4" && \
 387 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 388         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 389         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 390         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 391         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 392         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 393         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 394 }
 395 ])dnl
 396 dnl ---------------------------------------------------------------------------
 397 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 398 dnl --------------
 399 dnl Allow user to disable a normally-on option.
 400 AC_DEFUN([CF_ARG_DISABLE],
 401 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 402 dnl ---------------------------------------------------------------------------
 403 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 404 dnl -------------
 405 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 406 dnl values.
 407 dnl
 408 dnl Parameters:
 409 dnl $1 = option name
 410 dnl $2 = help-string
 411 dnl $3 = action to perform if option is not default
 412 dnl $4 = action if perform if option is default
 413 dnl $5 = default option value (either 'yes' or 'no')
 414 AC_DEFUN([CF_ARG_OPTION],
 415 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 416         if test "$enableval" != "$5" ; then
 417 ifelse([$3],,[    :]dnl
 418 ,[    $3]) ifelse([$4],,,[
 419         else
 420                 $4])
 421         fi],[enableval=$5 ifelse([$4],,,[
 422         $4
 423 ])dnl
 424 ])])dnl
 425 dnl ---------------------------------------------------------------------------
 426 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
 427 dnl -----------
 428 dnl Check for suitable "ar" (archiver) options for updating an archive.
 429 dnl
 430 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 431 dnl as well as a workaround for breakage of make's archive rules by the GNU
 432 dnl binutils "ar" program.
 433 AC_DEFUN([CF_AR_FLAGS],[
 434 AC_REQUIRE([CF_PROG_AR])
 435
 436 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 437         cf_cv_ar_flags=unknown
 438         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 439         do
 440
 441                 # check if $ARFLAGS already contains this choice
 442                 if test "x$ARFLAGS" != "x" ; then
 443                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 444                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 445                                 cf_cv_ar_flags=
 446                                 break
 447                         fi
 448                 fi
 449
 450                 rm -f conftest.$ac_cv_objext
 451                 rm -f conftest.a
 452
 453                 cat >conftest.$ac_ext <<EOF
 454 #line __oline__ "configure"
 455 int     testdata[[3]] = { 123, 456, 789 };
 456 EOF
 457                 if AC_TRY_EVAL(ac_compile) ; then
 458                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 459                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 460                         if test -f conftest.a ; then
 461                                 cf_cv_ar_flags=$cf_ar_flags
 462                                 break
 463                         fi
 464                 else
 465                         CF_VERBOSE(cannot compile test-program)
 466                         break
 467                 fi
 468         done
 469         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 470 ])
 471
 472 if test -n "$ARFLAGS" ; then
 473         if test -n "$cf_cv_ar_flags" ; then
 474                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 475         fi
 476 else
 477         ARFLAGS=$cf_cv_ar_flags
 478 fi
 479
 480 AC_SUBST(ARFLAGS)
 481 ])
 482 dnl ---------------------------------------------------------------------------
 483 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 484 dnl -----------------
 485 dnl Check if awk can handle big strings using printf.  Some older versions of
 486 dnl awk choke on large strings passed via "%s".
 487 dnl
 488 dnl $1 = desired string size
 489 dnl $2 = variable to set with result
 490 AC_DEFUN([CF_AWK_BIG_PRINTF],
 491 [
 492         case x$AWK in
 493         (x)
 494                 eval $2=no
 495                 ;;
 496         (*)
 497                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 498                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 499                         eval $2=yes
 500                 else
 501                         eval $2=no
 502                 fi
 503                 ;;
 504         esac
 505 ])dnl
 506 dnl ---------------------------------------------------------------------------
 507 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 508 dnl ------------
 509 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 510 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 511 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 512 dnl
 513 dnl Treat the configuration-variable specially here, since we're directly
 514 dnl substituting its value (i.e., 1/0).
 515 dnl
 516 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 517 AC_DEFUN([CF_BOOL_DECL],
 518 [
 519 AC_MSG_CHECKING(if we should include stdbool.h)
 520
 521 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 522         AC_TRY_COMPILE([],[bool foo = false],
 523                 [cf_cv_header_stdbool_h=0],
 524                 [AC_TRY_COMPILE([
 525 #ifndef __BEOS__
 526 #include <stdbool.h>
 527 #endif
 528 ],[bool foo = false],
 529                         [cf_cv_header_stdbool_h=1],
 530                         [cf_cv_header_stdbool_h=0])])])
 531
 532 if test "$cf_cv_header_stdbool_h" = 1
 533 then    AC_MSG_RESULT(yes)
 534 else    AC_MSG_RESULT(no)
 535 fi
 536
 537 AC_MSG_CHECKING([for builtin bool type])
 538
 539 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 540         AC_TRY_COMPILE([
 541 #include <stdio.h>
 542 #include <sys/types.h>
 543 ],[bool x = false],
 544                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 545                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 546         ])
 547
 548 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 549 then    AC_MSG_RESULT(yes)
 550 else    AC_MSG_RESULT(no)
 551 fi
 552 ])dnl
 553 dnl ---------------------------------------------------------------------------
 554 dnl CF_BOOL_SIZE version: 14 updated: 2015/04/17 21:13:04
 555 dnl ------------
 556 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 557 dnl Don't bother looking for bool.h, since it's been deprecated.
 558 dnl
 559 dnl If the current compiler is C rather than C++, we get the bool definition
 560 dnl from <stdbool.h>.
 561 AC_DEFUN([CF_BOOL_SIZE],
 562 [
 563 AC_MSG_CHECKING([for size of bool])
 564 AC_CACHE_VAL(cf_cv_type_of_bool,[
 565         rm -f cf_test.out
 566         AC_TRY_RUN([
 567 #include <stdlib.h>
 568 #include <stdio.h>
 569
 570 #if defined(__cplusplus)
 571
 572 #ifdef HAVE_GXX_BUILTIN_H
 573 #include <g++/builtin.h>
 574 #elif HAVE_GPP_BUILTIN_H
 575 #include <gpp/builtin.h>
 576 #elif HAVE_BUILTIN_H
 577 #include <builtin.h>
 578 #endif
 579
 580 #else
 581
 582 #if $cf_cv_header_stdbool_h
 583 #include <stdbool.h>
 584 #endif
 585
 586 #endif
 587
 588 int main()
 589 {
 590         FILE *fp = fopen("cf_test.out", "w");
 591         if (fp != 0) {
 592                 bool x = true;
 593                 if ((bool)(-x) >= 0)
 594                         fputs("unsigned ", fp);
 595                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 596                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 597                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 598                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 599                 fclose(fp);
 600         }
 601         ${cf_cv_main_return:-return}(0);
 602 }
 603                 ],
 604                 [cf_cv_type_of_bool=`cat cf_test.out`
 605                  if test -z "$cf_cv_type_of_bool"; then
 606                    cf_cv_type_of_bool=unknown
 607                  fi],
 608                 [cf_cv_type_of_bool=unknown],
 609                 [cf_cv_type_of_bool=unknown])
 610         ])
 611         rm -f cf_test.out
 612 AC_MSG_RESULT($cf_cv_type_of_bool)
 613 if test "$cf_cv_type_of_bool" = unknown ; then
 614         case .$NCURSES_BOOL in
 615         (.auto|.) NCURSES_BOOL=unsigned;;
 616         esac
 617         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 618         cf_cv_type_of_bool=$NCURSES_BOOL
 619 fi
 620 ])dnl
 621 dnl ---------------------------------------------------------------------------
 622 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 623 dnl -----------
 624 dnl If we're cross-compiling, allow the user to override the tools and their
 625 dnl options.  The configure script is oriented toward identifying the host
 626 dnl compiler, etc., but we need a build compiler to generate parts of the
 627 dnl source.
 628 dnl
 629 dnl $1 = default for $CPPFLAGS
 630 dnl $2 = default for $LIBS
 631 AC_DEFUN([CF_BUILD_CC],[
 632 CF_ACVERSION_CHECK(2.52,,
 633         [AC_REQUIRE([CF_PROG_EXT])])
 634 if test "$cross_compiling" = yes ; then
 635
 636         # defaults that we might want to override
 637         : ${BUILD_CFLAGS:=''}
 638         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 639         : ${BUILD_LDFLAGS:=''}
 640         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 641         : ${BUILD_EXEEXT:='$x'}
 642         : ${BUILD_OBJEXT:='o'}
 643
 644         AC_ARG_WITH(build-cc,
 645                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 646                 [BUILD_CC="$withval"],
 647                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 648         AC_MSG_CHECKING(for native build C compiler)
 649         AC_MSG_RESULT($BUILD_CC)
 650
 651         AC_MSG_CHECKING(for native build C preprocessor)
 652         AC_ARG_WITH(build-cpp,
 653                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 654                 [BUILD_CPP="$withval"],
 655                 [BUILD_CPP='${BUILD_CC} -E'])
 656         AC_MSG_RESULT($BUILD_CPP)
 657
 658         AC_MSG_CHECKING(for native build C flags)
 659         AC_ARG_WITH(build-cflags,
 660                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 661                 [BUILD_CFLAGS="$withval"])
 662         AC_MSG_RESULT($BUILD_CFLAGS)
 663
 664         AC_MSG_CHECKING(for native build C preprocessor-flags)
 665         AC_ARG_WITH(build-cppflags,
 666                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 667                 [BUILD_CPPFLAGS="$withval"])
 668         AC_MSG_RESULT($BUILD_CPPFLAGS)
 669
 670         AC_MSG_CHECKING(for native build linker-flags)
 671         AC_ARG_WITH(build-ldflags,
 672                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 673                 [BUILD_LDFLAGS="$withval"])
 674         AC_MSG_RESULT($BUILD_LDFLAGS)
 675
 676         AC_MSG_CHECKING(for native build linker-libraries)
 677         AC_ARG_WITH(build-libs,
 678                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 679                 [BUILD_LIBS="$withval"])
 680         AC_MSG_RESULT($BUILD_LIBS)
 681
 682         # this assumes we're on Unix.
 683         BUILD_EXEEXT=
 684         BUILD_OBJEXT=o
 685
 686         : ${BUILD_CC:='${CC}'}
 687
 688         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 689                 AC_MSG_ERROR([Cross-build requires two compilers.
 690 Use --with-build-cc to specify the native compiler.])
 691         fi
 692
 693 else
 694         : ${BUILD_CC:='${CC}'}
 695         : ${BUILD_CPP:='${CPP}'}
 696         : ${BUILD_CFLAGS:='${CFLAGS}'}
 697         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 698         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 699         : ${BUILD_LIBS:='${LIBS}'}
 700         : ${BUILD_EXEEXT:='$x'}
 701         : ${BUILD_OBJEXT:='o'}
 702 fi
 703
 704 AC_SUBST(BUILD_CC)
 705 AC_SUBST(BUILD_CPP)
 706 AC_SUBST(BUILD_CFLAGS)
 707 AC_SUBST(BUILD_CPPFLAGS)
 708 AC_SUBST(BUILD_LDFLAGS)
 709 AC_SUBST(BUILD_LIBS)
 710 AC_SUBST(BUILD_EXEEXT)
 711 AC_SUBST(BUILD_OBJEXT)
 712 ])dnl
 713 dnl ---------------------------------------------------------------------------
 714 dnl CF_CC_ENV_FLAGS version: 6 updated: 2016/08/29 20:57:00
 715 dnl ---------------
 716 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 717 dnl into CC.  This will not help with broken scripts that wrap the compiler
 718 dnl with options, but eliminates a more common category of user confusion.
 719 dnl
 720 dnl In particular, it addresses the problem of being able to run the C
 721 dnl preprocessor in a consistent manner.
 722 dnl
 723 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 724 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 725 dnl outweighs that limitation.
 726 AC_DEFUN([CF_CC_ENV_FLAGS],
 727 [
 728 # This should have been defined by AC_PROG_CC
 729 : ${CC:=cc}
 730
 731 AC_MSG_CHECKING(\$CC variable)
 732 case "$CC" in
 733 (*[[\ \ ]]-*)
 734         AC_MSG_RESULT(broken)
 735         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 736         # humor him...
 737         cf_flags=`echo "$CC" | sed -e 's/^.*[[  ]]\(-[[^        ]]\)/\1/'`
 738         CC=`echo "$CC " | sed -e 's/[[  ]]-[[^  ]].*$//' -e 's/[[       ]]*$//'`
 739         for cf_arg in $cf_flags
 740         do
 741                 case "x$cf_arg" in
 742                 (x-[[IUDfgOW]]*)
 743                         CF_ADD_CFLAGS($cf_flags)
 744                         ;;
 745                 (*)
 746                         CC="$CC $cf_arg"
 747                         ;;
 748                 esac
 749         done
 750         CF_VERBOSE(resulting CC: '$CC')
 751         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 752         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 753         ;;
 754 (*)
 755         AC_MSG_RESULT(ok)
 756         ;;
 757 esac
 758 ])dnl
 759 dnl ---------------------------------------------------------------------------
 760 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 761 dnl ---------------
 762 dnl Determine the default configuration into which we'll install ncurses.  This
 763 dnl can be overridden by the user's command-line options.  There's two items to
 764 dnl look for:
 765 dnl     1. the prefix (e.g., /usr)
 766 dnl     2. the header files (e.g., /usr/include/ncurses)
 767 dnl We'll look for a previous installation of ncurses and use the same defaults.
 768 dnl
 769 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 770 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 771 dnl programs from a vendor's.
 772 AC_DEFUN([CF_CFG_DEFAULTS],
 773 [
 774 AC_MSG_CHECKING(for prefix)
 775 if test "x$prefix" = "xNONE" ; then
 776         case "$cf_cv_system_name" in
 777                 # non-vendor systems don't have a conflict
 778         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 779                 prefix=/usr
 780                 ;;
 781         (*)     prefix=$ac_default_prefix
 782                 ;;
 783         esac
 784 fi
 785 AC_MSG_RESULT($prefix)
 786
 787 if test "x$prefix" = "xNONE" ; then
 788 AC_MSG_CHECKING(for default include-directory)
 789 test -n "$verbose" && echo 1>&AC_FD_MSG
 790 for cf_symbol in \
 791         $includedir \
 792         $includedir/ncurses \
 793         $prefix/include \
 794         $prefix/include/ncurses \
 795         /usr/local/include \
 796         /usr/local/include/ncurses \
 797         /usr/include \
 798         /usr/include/ncurses
 799 do
 800         cf_dir=`eval echo $cf_symbol`
 801         if test -f $cf_dir/curses.h ; then
 802         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 803                 includedir="$cf_symbol"
 804                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 805                 break
 806         fi
 807         fi
 808         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 809 done
 810 AC_MSG_RESULT($includedir)
 811 fi
 812 ])dnl
 813 dnl ---------------------------------------------------------------------------
 814 dnl CF_CGETENT version: 5 updated: 2012/10/06 17:56:13
 815 dnl ----------
 816 dnl Check if the terminal-capability database functions are available.  If not,
 817 dnl ncurses has a much-reduced version.
 818 AC_DEFUN([CF_CGETENT],[
 819 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 820 AC_TRY_LINK([
 821 #include <stdlib.h>],[
 822         char temp[128];
 823         char *buf = temp;
 824         char *db_array = temp;
 825         cgetent(&buf, &db_array, "vt100");
 826         cgetcap(buf, "tc", '=');
 827         cgetmatch(buf, "tc");
 828         ],
 829         [cf_cv_cgetent=yes],
 830         [cf_cv_cgetent=no])
 831 ])
 832
 833 if test "$cf_cv_cgetent" = yes
 834 then
 835         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 836 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 837 AC_TRY_LINK([
 838 #include <stdlib.h>],[
 839         char temp[128];
 840         char *buf = temp;
 841 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 842         const char *db_array = temp;
 843         cgetent(&buf, &db_array, "vt100");
 844 #endif
 845         cgetcap(buf, "tc", '=');
 846         cgetmatch(buf, "tc");
 847         ],
 848         [cf_cv_cgetent_const=yes],
 849         [cf_cv_cgetent_const=no])
 850 ])
 851         if test "$cf_cv_cgetent_const" = yes
 852         then
 853                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 854         fi
 855 fi
 856 ])dnl
 857 dnl ---------------------------------------------------------------------------
 858 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 859 dnl --------------
 860 dnl Check if we're accidentally using a cache from a different machine.
 861 dnl Derive the system name, as a check for reusing the autoconf cache.
 862 dnl
 863 dnl If we've packaged config.guess and config.sub, run that (since it does a
 864 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 865 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 866 dnl which is useful in cross-compiles.
 867 dnl
 868 dnl Note: we would use $ac_config_sub, but that is one of the places where
 869 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 870 AC_DEFUN([CF_CHECK_CACHE],
 871 [
 872 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 873         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 874         system_name="$host_os"
 875 else
 876         system_name="`(uname -s -r) 2>/dev/null`"
 877         if test -z "$system_name" ; then
 878                 system_name="`(hostname) 2>/dev/null`"
 879         fi
 880 fi
 881 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 882 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 883
 884 test -z "$system_name" && system_name="$cf_cv_system_name"
 885 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 886
 887 if test ".$system_name" != ".$cf_cv_system_name" ; then
 888         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 889         AC_MSG_ERROR("Please remove config.cache and try again.")
 890 fi
 891 ])dnl
 892 dnl ---------------------------------------------------------------------------
 893 dnl CF_CHECK_ERRNO version: 12 updated: 2015/04/18 08:56:57
 894 dnl --------------
 895 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 896 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 897 dnl ourselves.
 898 dnl
 899 dnl $1 = the name to check
 900 dnl $2 = the assumed type
 901 AC_DEFUN([CF_CHECK_ERRNO],
 902 [
 903 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 904         AC_TRY_COMPILE([
 905 #ifdef HAVE_STDLIB_H
 906 #include <stdlib.h>
 907 #endif
 908 #include <stdio.h>
 909 #include <sys/types.h>
 910 #include <errno.h> ],
 911         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 912         [cf_cv_dcl_$1=yes],
 913         [cf_cv_dcl_$1=no])
 914 ])
 915
 916 if test "$cf_cv_dcl_$1" = no ; then
 917         CF_UPPER(cf_result,decl_$1)
 918         AC_DEFINE_UNQUOTED($cf_result)
 919 fi
 920
 921 # It's possible (for near-UNIX clones) that the data doesn't exist
 922 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 923 ])dnl
 924 dnl ---------------------------------------------------------------------------
 925 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
 926 dnl --------------------
 927 dnl Check for existence of external data in the current set of libraries.  If
 928 dnl we can modify it, it's real enough.
 929 dnl $1 = the name to check
 930 dnl $2 = its type
 931 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 932 [
 933 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 934         AC_TRY_LINK([
 935 #undef $1
 936 extern $2 $1;
 937 ],
 938         [$1 = 2],
 939         [cf_cv_have_$1=yes],
 940         [cf_cv_have_$1=no])
 941 ])
 942
 943 if test "$cf_cv_have_$1" = yes ; then
 944         CF_UPPER(cf_result,have_$1)
 945         AC_DEFINE_UNQUOTED($cf_result)
 946 fi
 947
 948 ])dnl
 949 dnl ---------------------------------------------------------------------------
 950 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 951 dnl -------------------
 952 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 953 dnl is not "weak" - warn about this because it can create problems linking
 954 dnl applications with ncurses.
 955 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 956 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 957
 958 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 959 cf_cv_check_gpm_wgetch=unknown
 960 if test "$cross_compiling" != yes ; then
 961
 962 cat >conftest.$ac_ext <<CF_EOF
 963 #include <gpm.h>
 964 int main()
 965 {
 966         Gpm_Wgetch();
 967         ${cf_cv_main_return:-return}(0);
 968 }
 969 CF_EOF
 970
 971         cf_save_LIBS="$LIBS"
 972         # This only works if we can look at the symbol table.  If a shared
 973         # library is stripped for install, we cannot use that.  So we're forced
 974         # to rely on the static library, noting that some packagers may not
 975         # include it.
 976         LIBS="-static -lgpm -dynamic $LIBS"
 977         if AC_TRY_EVAL(ac_compile) ; then
 978                 if AC_TRY_EVAL(ac_link) ; then
 979                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 980                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 981                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 982                 fi
 983         fi
 984         rm -rf conftest*
 985         LIBS="$cf_save_LIBS"
 986 fi
 987 ])
 988
 989 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 990         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 991 fi
 992 ])])dnl
 993 dnl ---------------------------------------------------------------------------
 994 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
 995 dnl ------------------------
 996 dnl Show the version of libtool
 997 dnl
 998 dnl Save the version in a cache variable - this is not entirely a good thing,
 999 dnl but the version string from libtool is very ugly, and for bug reports it
1000 dnl might be useful to have the original string.
1001 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1002 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1003 then
1004         AC_MSG_CHECKING(version of $LIBTOOL)
1005         CF_LIBTOOL_VERSION
1006         AC_MSG_RESULT($cf_cv_libtool_version)
1007         if test -z "$cf_cv_libtool_version" ; then
1008                 AC_MSG_ERROR(This is not GNU libtool)
1009         fi
1010 else
1011         AC_MSG_ERROR(GNU libtool has not been found)
1012 fi
1013 ])dnl
1014 dnl ---------------------------------------------------------------------------
1015 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
1016 dnl ----------------
1017 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1018 AC_DEFUN([CF_CHECK_WCHAR_H],[
1019 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1020 AC_TRY_COMPILE(
1021 [
1022 #include <stdlib.h>
1023 #include <wchar.h>
1024 ],[
1025         wint_t foo = 0;
1026         int bar = iswpunct(foo)],
1027         [cf_cv_wchar_h_okay=yes],
1028         [cf_cv_wchar_h_okay=no])])
1029
1030 if test $cf_cv_wchar_h_okay = no
1031 then
1032         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1033 fi
1034 ])dnl
1035 dnl ---------------------------------------------------------------------------
1036 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 1 updated: 2015/12/19 17:47:56
1037 dnl -------------------------
1038 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1039 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1040 dnl
1041 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1042 dnl all of those were combined into a page of useful graphics characters.
1043 dnl
1044 dnl So far, so good.
1045 dnl
1046 dnl However, while they are useful, there are other considerations.  CJK
1047 dnl is (because of poor device resolution) often rendered as double-width
1048 dnl characters.  So... for these generally-useful characters, what should
1049 dnl be the width (to make them consistent with adjacent characters)?
1050 dnl
1051 dnl The obvious choice would have been to make this locale-dependent, and use
1052 dnl wcwidth() to tell applications what the actual width is.  That was too
1053 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1054 dnl See for example
1055 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1056 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1057 dnl
1058 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1059 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1060 dnl instance, it lists half (44/96) of the Latin-1 characters as
1061 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1062 dnl
1063 dnl What this means for the implementor is that on some systems wcwidth() can
1064 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1065 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1066 dnl characters).  These do not necessarily match the behavior of the terminal
1067 dnl emulator.  xterm, for instance, does an optional startup check to find if
1068 dnl this problem (or similar) exists with the system's locale tables, rejecting
1069 dnl them if they are too unreliable.
1070 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1071 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1072 cat >conftest.in <<CF_EOF
1073 -       VT100 symbols
1074 0x250c  upper left corner
1075 0x2514  lower left corner
1076 0x2510  upper right corner
1077 0x2518  lower right corner
1078 0x251c  tee pointing left
1079 0x2524  tee pointing right
1080 0x2534  tee pointing up
1081 0x252c  tee pointing down
1082 0x2500  horizontal line
1083 0x2502  vertical line
1084 0x253c  large plus or crossover
1085 0x23ba  scan line 1
1086 0x23bd  scan line 9
1087 0x25c6  diamond
1088 0x2592  checker board (stipple)
1089 0x00b0  degree symbol
1090 0x00b1  plus/minus
1091 0x00b7  bullet
1092 -       Teletype 5410v1 symbols
1093 0x2190  arrow pointing left
1094 0x2192  arrow pointing right
1095 0x2193  arrow pointing down
1096 0x2191  arrow pointing up
1097 0x2592  board of squares
1098 0x2603  lantern symbol
1099 0x25ae  solid square block
1100 -       these defaults were invented for ncurses
1101 0x23bb  scan line 3
1102 0x23bc  scan line 7
1103 0x2264  less-than-or-equal-to
1104 0x2265  greater-than-or-equal-to
1105 0x03c0  greek pi
1106 0x2260  not-equal
1107 0x00a3  pound-sterling symbol
1108 -       thick-line-drawing
1109 0x250f  upper left corner
1110 0x2517  lower left corner
1111 0x2513  upper right corner
1112 0x251b  lower right corner
1113 0x2523  tee pointing left
1114 0x252b  tee pointing right
1115 0x253b  tee pointing up
1116 0x2533  tee pointing down
1117 0x2501  horizontal line
1118 0x2503  vertical line
1119 0x254b  large plus or crossover
1120 -       double-line-drawing
1121 0x2554  upper left corner
1122 0x255a  lower left corner
1123 0x2557  upper right corner
1124 0x255d  lower right corner
1125 0x2563  tee pointing left
1126 0x2560  tee pointing right
1127 0x2569  tee pointing up
1128 0x2566  tee pointing down
1129 0x2550  horizontal line
1130 0x2551  vertical line
1131 0x256c  large plus or crossover
1132 CF_EOF
1133 AC_TRY_RUN([
1134 #include <locale.h>
1135 #include <stdio.h>
1136 #include <wchar.h>
1137
1138 #define MY_LEN 80
1139
1140 int
1141 main(void)
1142 {
1143         FILE *fp;
1144         int value;
1145         char buffer[MY_LEN + 1];
1146         char notes[MY_LEN + 1];
1147         int totals = 0;
1148         int passed = 0;
1149
1150         if (setlocale(LC_ALL, "en_US.UTF8") ||
1151                 setlocale(LC_ALL, "en_US.UTF-8") ||
1152                 setlocale(LC_ALL, "en_US.utf8") ||
1153                 setlocale(LC_ALL, "en_US.utf-8")) {
1154                 if ((fp = fopen("conftest.in", "r")) != 0) {
1155                         while (fgets(buffer, MY_LEN, fp) != 0) {
1156                                 if (*buffer == '-') {
1157                                         fprintf(stderr, "\t%s", buffer);
1158                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1159                                         ++totals;
1160                                         if (wcwidth(value) == 1)
1161                                                 ++passed;
1162                                         fprintf(stderr, "%d\t%s", wcwidth(value), buffer);
1163                                 } else {
1164                                         fprintf(stderr, "?\t%s", buffer);
1165                                 }
1166                         }
1167                 }
1168         }
1169         fprintf(stderr, "%d/%d passed wcwidth/graphics check\n", passed, totals);
1170         return (totals == passed) ? 0 : 1;
1171 }
1172 ],
1173 [cf_cv_wcwidth_graphics=yes],
1174 [cf_cv_wcwidth_graphics=no],
1175 [cf_cv_wcwidth_graphics=unknown])
1176 ])
1177 ])dnl
1178 dnl ---------------------------------------------------------------------------
1179 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
1180 dnl -----------------
1181 dnl Check if the given compiler is really clang.  clang's C driver defines
1182 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1183 dnl not ignore some gcc options.
1184 dnl
1185 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1186 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1187 dnl the wrappers for gcc and g++ warnings.
1188 dnl
1189 dnl $1 = GCC (default) or GXX
1190 dnl $2 = CLANG_COMPILER (default)
1191 dnl $3 = CFLAGS (default) or CXXFLAGS
1192 AC_DEFUN([CF_CLANG_COMPILER],[
1193 ifelse([$2],,CLANG_COMPILER,[$2])=no
1194
1195 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1196         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1197         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1198         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
1199         AC_TRY_COMPILE([],[
1200 #ifdef __clang__
1201 #else
1202 make an error
1203 #endif
1204 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1205 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1206 ],[])
1207         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1208         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1209 fi
1210 ])
1211 dnl ---------------------------------------------------------------------------
1212 dnl CF_CPP_PARAM_INIT version: 6 updated: 2012/10/06 17:56:13
1213 dnl -----------------
1214 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1215 dnl is a late feature for the standard and is not in some recent compilers
1216 dnl (1999/9/11).
1217 AC_DEFUN([CF_CPP_PARAM_INIT],
1218 [
1219 if test -n "$CXX"; then
1220 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1221         AC_LANG_SAVE
1222         AC_LANG_CPLUSPLUS
1223         AC_TRY_RUN([
1224 class TEST {
1225 private:
1226         int value;
1227 public:
1228         TEST(int x = 1);
1229         ~TEST();
1230 };
1231
1232 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1233 {
1234         value = x;
1235 }
1236 int main() { }
1237 ],
1238         [cf_cv_cpp_param_init=yes],
1239         [cf_cv_cpp_param_init=no],
1240         [cf_cv_cpp_param_init=unknown])
1241         AC_LANG_RESTORE
1242 ])
1243 fi
1244 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1245 ])dnl
1246 dnl ---------------------------------------------------------------------------
1247 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1248 dnl ------------------
1249 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1250 dnl not be supported in g++ before 3.0
1251 AC_DEFUN([CF_CPP_STATIC_CAST],
1252 [
1253 if test -n "$CXX"; then
1254
1255 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1256         AC_LANG_SAVE
1257         AC_LANG_CPLUSPLUS
1258
1259         AC_TRY_COMPILE([
1260 class NCursesPanel
1261 {
1262 public:
1263   NCursesPanel(int nlines,
1264                int ncols,
1265                int begin_y = 0,
1266                int begin_x = 0)
1267   {
1268   }
1269   NCursesPanel();
1270   ~NCursesPanel();
1271 };
1272
1273 template<class T> class NCursesUserPanel : public NCursesPanel
1274 {
1275 public:
1276   NCursesUserPanel (int nlines,
1277                     int ncols,
1278                     int begin_y = 0,
1279                     int begin_x = 0,
1280                     const T* p_UserData = static_cast<T*>(0))
1281     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1282   {
1283   };
1284   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1285   {
1286   };
1287
1288   virtual ~NCursesUserPanel() {};
1289 };
1290 ],[
1291         const char* p_UserData = static_cast<char*>(0)],
1292         [cf_cv_cpp_static_cast=yes],
1293         [cf_cv_cpp_static_cast=no])
1294
1295         AC_LANG_RESTORE
1296 ])
1297
1298 fi
1299
1300 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1301 ])dnl
1302 dnl ---------------------------------------------------------------------------
1303 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1304 dnl ---------------
1305 dnl Setup special archiver flags for given compilers.
1306 AC_DEFUN([CF_CXX_AR_FLAGS],[
1307         CXX_AR='$(AR)'
1308         CXX_ARFLAGS='$(ARFLAGS)'
1309         case $cf_cv_system_name in
1310         (irix*)
1311             if test "$GXX" != yes ; then
1312                 CXX_AR='$(CXX)'
1313                 CXX_ARFLAGS='-ar -o'
1314             fi
1315             ;;
1316         (sco3.2v5*)
1317             CXXLDFLAGS="-u main"
1318             ;;
1319         (solaris2*)
1320             if test "$GXX" != yes ; then
1321                 CXX_AR='$(CXX)'
1322                 CXX_ARFLAGS='-xar -o'
1323             fi
1324             ;;
1325         esac
1326         AC_SUBST(CXXLDFLAGS)
1327         AC_SUBST(CXX_AR)
1328         AC_SUBST(CXX_ARFLAGS)
1329 ])dnl
1330 dnl ---------------------------------------------------------------------------
1331 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1332 dnl -------------------------
1333 dnl For c++, check if iostream uses "std::" namespace.
1334 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1335 AC_CHECK_HEADERS(iostream)
1336 if test x"$ac_cv_header_iostream" = xyes ; then
1337         AC_MSG_CHECKING(if iostream uses std-namespace)
1338         AC_TRY_COMPILE([
1339 #include <iostream>
1340 using std::endl;
1341 using std::cerr;],[
1342 cerr << "testing" << endl;
1343 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1344         AC_MSG_RESULT($cf_iostream_namespace)
1345         if test "$cf_iostream_namespace" = yes ; then
1346                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1347         fi
1348 fi
1349 ])dnl
1350 dnl ---------------------------------------------------------------------------
1351 dnl CF_C_INLINE version: 5 updated: 2015/04/18 08:56:57
1352 dnl -----------
1353 dnl Check if the C compiler supports "inline".
1354 dnl $1 is the name of a shell variable to set if inline is supported
1355 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1356 AC_DEFUN([CF_C_INLINE],[
1357 AC_C_INLINE
1358 $1=
1359 if test "$ac_cv_c_inline" != no ; then
1360         $1=inline
1361         if test "$INTEL_COMPILER" = yes
1362         then
1363                 :
1364         elif test "$CLANG_COMPILER" = yes
1365         then
1366                 :
1367         elif test "$GCC" = yes
1368         then
1369                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1370                 cf_save_CFLAGS=$CFLAGS
1371                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1372                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1373                 [${cf_cv_main_return:-return} foo()],
1374                 [cf_cv_gcc_inline=yes],
1375                 [cf_cv_gcc_inline=no])
1376                 CFLAGS=$cf_save_CFLAGS
1377                 ])
1378                 if test "$cf_cv_gcc_inline" = yes ; then
1379                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1380                 fi
1381         fi
1382 fi
1383 AC_SUBST($1)
1384 ])dnl
1385 dnl ---------------------------------------------------------------------------
1386 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1387 dnl ----------
1388 dnl "dirname" is not portable, so we fake it with a shell script.
1389 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1390 dnl ---------------------------------------------------------------------------
1391 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1392 dnl ---------------
1393 AC_DEFUN([CF_DIRS_TO_MAKE],
1394 [
1395 DIRS_TO_MAKE="lib"
1396 for cf_item in $cf_list_models
1397 do
1398         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1399         for cf_item2 in $DIRS_TO_MAKE
1400         do
1401                 test $cf_item2 = $cf_subdir && break
1402         done
1403         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1404 done
1405 for cf_dir in $DIRS_TO_MAKE
1406 do
1407         test ! -d $cf_dir && mkdir $cf_dir
1408 done
1409 AC_SUBST(DIRS_TO_MAKE)
1410 ])dnl
1411 dnl ---------------------------------------------------------------------------
1412 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1413 dnl ---------------
1414 dnl You can always use "make -n" to see the actual options, but it's hard to
1415 dnl pick out/analyze warning messages when the compile-line is long.
1416 dnl
1417 dnl Sets:
1418 dnl     ECHO_LT - symbol to control if libtool is verbose
1419 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1420 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1421 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1422 dnl     ECHO_CC - symbol to put before any "cc" line
1423 dnl
1424 AC_DEFUN([CF_DISABLE_ECHO],[
1425 AC_MSG_CHECKING(if you want to see long compiling messages)
1426 CF_ARG_DISABLE(echo,
1427         [  --disable-echo          do not display "compiling" commands],
1428         [
1429         ECHO_LT='--silent'
1430         ECHO_LD='@echo linking [$]@;'
1431         RULE_CC='@echo compiling [$]<'
1432         SHOW_CC='@echo compiling [$]@'
1433         ECHO_CC='@'
1434 ],[
1435         ECHO_LT=''
1436         ECHO_LD=''
1437         RULE_CC=''
1438         SHOW_CC=''
1439         ECHO_CC=''
1440 ])
1441 AC_MSG_RESULT($enableval)
1442 AC_SUBST(ECHO_LT)
1443 AC_SUBST(ECHO_LD)
1444 AC_SUBST(RULE_CC)
1445 AC_SUBST(SHOW_CC)
1446 AC_SUBST(ECHO_CC)
1447 ])dnl
1448 dnl ---------------------------------------------------------------------------
1449 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1450 dnl ------------------------
1451 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1452 AC_MSG_CHECKING(if we want to use GNAT projects)
1453 CF_ARG_DISABLE(gnat-projects,
1454         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1455         [enable_gnat_projects=no],
1456         [enable_gnat_projects=yes])
1457 AC_MSG_RESULT($enable_gnat_projects)
1458 ])dnl
1459 dnl ---------------------------------------------------------------------------
1460 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1461 dnl ----------------
1462 dnl Combine no-leak checks with the libraries or tools that are used for the
1463 dnl checks.
1464 AC_DEFUN([CF_DISABLE_LEAKS],[
1465
1466 AC_REQUIRE([CF_WITH_DMALLOC])
1467 AC_REQUIRE([CF_WITH_DBMALLOC])
1468 AC_REQUIRE([CF_WITH_VALGRIND])
1469
1470 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1471 AC_ARG_ENABLE(leaks,
1472         [  --disable-leaks         test: free permanent memory, analyze leaks],
1473         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1474         : ${with_no_leaks:=no})
1475 AC_MSG_RESULT($with_no_leaks)
1476
1477 if test "$with_no_leaks" = yes ; then
1478         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1479         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1480 fi
1481 ])dnl
1482 dnl ---------------------------------------------------------------------------
1483 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1484 dnl --------------------------
1485 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1486 dnl the older "-version-info" feature.  The newer feature allows us to use
1487 dnl version numbering on shared libraries which make them compatible with
1488 dnl various systems.
1489 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1490 [
1491 AC_MSG_CHECKING(if libtool -version-number should be used)
1492 CF_ARG_DISABLE(libtool-version,
1493         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1494         [cf_libtool_version=no],
1495         [cf_libtool_version=yes])
1496 AC_MSG_RESULT($cf_libtool_version)
1497
1498 if test "$cf_libtool_version" = yes ; then
1499         LIBTOOL_VERSION="-version-number"
1500 else
1501         LIBTOOL_VERSION="-version-info"
1502         case "x$VERSION" in
1503         (x)
1504                 AC_MSG_WARN(VERSION was not set)
1505                 ;;
1506         (x*.*.*)
1507                 ABI_VERSION="$VERSION"
1508                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1509                 ;;
1510         (x*:*:*)
1511                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1512                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1513                 ;;
1514         (*)
1515                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1516                 ;;
1517         esac
1518 fi
1519
1520 AC_SUBST(ABI_VERSION)
1521 AC_SUBST(LIBTOOL_VERSION)
1522 ])dnl
1523 dnl ---------------------------------------------------------------------------
1524 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1525 dnl ---------------------
1526 dnl The rpath-hack makes it simpler to build programs, particularly with the
1527 dnl *BSD ports which may have essential libraries in unusual places.  But it
1528 dnl can interfere with building an executable for the base system.  Use this
1529 dnl option in that case.
1530 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1531 [
1532 AC_MSG_CHECKING(if rpath-hack should be disabled)
1533 CF_ARG_DISABLE(rpath-hack,
1534         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1535         [cf_disable_rpath_hack=yes],
1536         [cf_disable_rpath_hack=no])
1537 AC_MSG_RESULT($cf_disable_rpath_hack)
1538 if test "$cf_disable_rpath_hack" = no ; then
1539         CF_RPATH_HACK
1540 fi
1541 ])
1542 dnl ---------------------------------------------------------------------------
1543 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
1544 dnl ------------------
1545 dnl This is the "--enable-pc-files" option, which is available if there is a
1546 dnl pkg-config configuration on the local machine.
1547 AC_DEFUN([CF_ENABLE_PC_FILES],[
1548 AC_REQUIRE([CF_PKG_CONFIG])
1549 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1550
1551 if test "x$PKG_CONFIG" != xnone
1552 then
1553         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1554 else
1555         AC_MSG_CHECKING(if we should install .pc files)
1556 fi
1557
1558 AC_ARG_ENABLE(pc-files,
1559         [  --enable-pc-files       generate and install .pc files for pkg-config],
1560         [enable_pc_files=$enableval],
1561         [enable_pc_files=no])
1562 AC_MSG_RESULT($enable_pc_files)
1563
1564 if test "x$enable_pc_files" != xno
1565 then
1566         MAKE_PC_FILES=
1567         case "x$PKG_CONFIG_LIBDIR" in
1568         (xno|xyes)
1569                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1570                 ;;
1571         (*)
1572                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1573                 ;;
1574         esac
1575 else
1576         MAKE_PC_FILES="#"
1577 fi
1578 AC_SUBST(MAKE_PC_FILES)
1579 ])dnl
1580 dnl ---------------------------------------------------------------------------
1581 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1582 dnl ---------------
1583 dnl Check if the rpath option should be used, setting cache variable
1584 dnl cf_cv_enable_rpath if so.
1585 AC_DEFUN([CF_ENABLE_RPATH],
1586 [
1587 AC_MSG_CHECKING(if rpath option should be used)
1588 AC_ARG_ENABLE(rpath,
1589 [  --enable-rpath          use rpath option when generating shared libraries],
1590 [cf_cv_enable_rpath=$enableval],
1591 [cf_cv_enable_rpath=no])
1592 AC_MSG_RESULT($cf_cv_enable_rpath)
1593 ])dnl
1594 dnl ---------------------------------------------------------------------------
1595 dnl CF_ENABLE_STRING_HACKS version: 4 updated: 2016/09/10 15:33:21
1596 dnl ----------------------
1597 dnl On a few platforms, the compiler and/or loader nags with untruthful
1598 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1599 dnl and implying that most uses of the recommended alternatives are correct.
1600 dnl
1601 dnl Factually speaking, no one has actually counted the number of uses of these
1602 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1603 dnl instances are meaningless compared to the hundreds of millions of lines of
1604 dnl existing C code.
1605 dnl
1606 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1607 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1608 dnl standard - but evolved through phases, and older implementations are likely
1609 dnl to yield surprising results, as documented in manpages on various systems.
1610 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1611 [
1612 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1613 AC_ARG_ENABLE(string-hacks,
1614         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1615         [with_string_hacks=$enableval],
1616         [with_string_hacks=no])
1617 AC_MSG_RESULT($with_string_hacks)
1618
1619 if test "x$with_string_hacks" = "xyes"; then
1620         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1621         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1622         AC_CHECK_FUNC(strlcat,,[
1623                 AC_CHECK_LIB(bsd,strlcat,[
1624                         CF_ADD_LIB(bsd)
1625                         AC_CHECK_HEADERS(bsd/string.h)
1626                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1627                         ])
1628                 ])
1629         AC_CHECK_FUNCS( strlcpy snprintf )
1630 fi
1631 ])dnl
1632 dnl ---------------------------------------------------------------------------
1633 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1634 dnl --------
1635 dnl Check if 'errno' is declared in <errno.h>
1636 AC_DEFUN([CF_ERRNO],
1637 [
1638 CF_CHECK_ERRNO(errno)
1639 ])dnl
1640 dnl ---------------------------------------------------------------------------
1641 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1642 dnl ---------------
1643 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1644 dnl math.h and builtin.h, only for ncurses
1645 AC_DEFUN([CF_ETIP_DEFINES],
1646 [
1647 AC_MSG_CHECKING(for special defines needed for etip.h)
1648 cf_save_CXXFLAGS="$CXXFLAGS"
1649 cf_result="none"
1650
1651 # etip.h includes ncurses.h which includes ncurses_dll.h
1652 # But ncurses_dll.h is generated - fix here.
1653 test -d include || mkdir include
1654 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1655
1656 for cf_math in "" MATH_H
1657 do
1658 for cf_excp in "" MATH_EXCEPTION
1659 do
1660         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1661         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1662         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1663 AC_TRY_COMPILE([
1664 #include <etip.h.in>
1665 ],[],[
1666         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1667         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1668         cf_result="$cf_math $cf_excp"
1669         break 2
1670 ],[])
1671 done
1672 done
1673 AC_MSG_RESULT($cf_result)
1674 CXXFLAGS="$cf_save_CXXFLAGS"
1675 ])
1676 dnl ---------------------------------------------------------------------------
1677 dnl CF_FIND_LINKAGE version: 20 updated: 2015/04/18 08:56:57
1678 dnl ---------------
1679 dnl Find a library (specifically the linkage used in the code fragment),
1680 dnl searching for it if it is not already in the library path.
1681 dnl See also CF_ADD_SEARCHPATH.
1682 dnl
1683 dnl Parameters (4-on are optional):
1684 dnl     $1 = headers for library entrypoint
1685 dnl     $2 = code fragment for library entrypoint
1686 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1687 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1688 dnl     $5 = action to perform if not successful
1689 dnl     $6 = module name, if not the same as the library name
1690 dnl     $7 = extra libraries
1691 dnl
1692 dnl Sets these variables:
1693 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1694 dnl     $cf_cv_header_path_$3 - include-directory if needed
1695 dnl     $cf_cv_library_path_$3 - library-directory if needed
1696 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1697 AC_DEFUN([CF_FIND_LINKAGE],[
1698
1699 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1700 # will be set on completion of the AC_TRY_LINK below.
1701 cf_cv_header_path_$3=
1702 cf_cv_library_path_$3=
1703
1704 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1705
1706 cf_save_LIBS="$LIBS"
1707
1708 AC_TRY_LINK([$1],[$2],[
1709         cf_cv_find_linkage_$3=yes
1710         cf_cv_header_path_$3=/usr/include
1711         cf_cv_library_path_$3=/usr/lib
1712 ],[
1713
1714 LIBS="-l$3 $7 $cf_save_LIBS"
1715
1716 AC_TRY_LINK([$1],[$2],[
1717         cf_cv_find_linkage_$3=yes
1718         cf_cv_header_path_$3=/usr/include
1719         cf_cv_library_path_$3=/usr/lib
1720         cf_cv_library_file_$3="-l$3"
1721 ],[
1722         cf_cv_find_linkage_$3=no
1723         LIBS="$cf_save_LIBS"
1724
1725         CF_VERBOSE(find linkage for $3 library)
1726         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1727
1728         cf_save_CPPFLAGS="$CPPFLAGS"
1729         cf_test_CPPFLAGS="$CPPFLAGS"
1730
1731         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1732         for cf_cv_header_path_$3 in $cf_search
1733         do
1734                 if test -d $cf_cv_header_path_$3 ; then
1735                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1736                         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1737                         AC_TRY_COMPILE([$1],[$2],[
1738                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1739                                 cf_cv_find_linkage_$3=maybe
1740                                 cf_test_CPPFLAGS="$CPPFLAGS"
1741                                 break],[
1742                                 CPPFLAGS="$cf_save_CPPFLAGS"
1743                                 ])
1744                 fi
1745         done
1746
1747         if test "$cf_cv_find_linkage_$3" = maybe ; then
1748
1749                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1750
1751                 cf_save_LIBS="$LIBS"
1752                 cf_save_LDFLAGS="$LDFLAGS"
1753
1754                 ifelse([$6],,,[
1755                 CPPFLAGS="$cf_test_CPPFLAGS"
1756                 LIBS="-l$3 $7 $cf_save_LIBS"
1757                 AC_TRY_LINK([$1],[$2],[
1758                         CF_VERBOSE(... found $3 library in system)
1759                         cf_cv_find_linkage_$3=yes])
1760                         CPPFLAGS="$cf_save_CPPFLAGS"
1761                         LIBS="$cf_save_LIBS"
1762                         ])
1763
1764                 if test "$cf_cv_find_linkage_$3" != yes ; then
1765                         CF_LIBRARY_PATH(cf_search,$3)
1766                         for cf_cv_library_path_$3 in $cf_search
1767                         do
1768                                 if test -d $cf_cv_library_path_$3 ; then
1769                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1770                                         CPPFLAGS="$cf_test_CPPFLAGS"
1771                                         LIBS="-l$3 $7 $cf_save_LIBS"
1772                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1773                                         AC_TRY_LINK([$1],[$2],[
1774                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1775                                         cf_cv_find_linkage_$3=yes
1776                                         cf_cv_library_file_$3="-l$3"
1777                                         break],[
1778                                         CPPFLAGS="$cf_save_CPPFLAGS"
1779                                         LIBS="$cf_save_LIBS"
1780                                         LDFLAGS="$cf_save_LDFLAGS"
1781                                         ])
1782                                 fi
1783                         done
1784                         CPPFLAGS="$cf_save_CPPFLAGS"
1785                         LDFLAGS="$cf_save_LDFLAGS"
1786                 fi
1787
1788         else
1789                 cf_cv_find_linkage_$3=no
1790         fi
1791         ],$7)
1792 ])
1793
1794 LIBS="$cf_save_LIBS"
1795
1796 if test "$cf_cv_find_linkage_$3" = yes ; then
1797 ifelse([$4],,[
1798         CF_ADD_INCDIR($cf_cv_header_path_$3)
1799         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1800         CF_ADD_LIB($3)
1801 ],[$4])
1802 else
1803 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1804 fi
1805 ])dnl
1806 dnl ---------------------------------------------------------------------------
1807 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
1808 dnl ------------------
1809 dnl Find an include-directory with the given leaf-name.  This is useful for
1810 dnl example with FreeBSD ports, which use this convention to distinguish
1811 dnl different versions of the same port.
1812 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1813         CF_SUBDIR_PATH(cf_search,$1,include)
1814         for cf_item in $cf_search
1815         do
1816                 case $cf_item in
1817                 (*/$1)
1818                         CF_ADD_INCDIR($cf_item)
1819                         ;;
1820                 esac
1821         done
1822 ])dnl
1823 dnl ---------------------------------------------------------------------------
1824 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
1825 dnl ------------------
1826 dnl Find a library-directory with the given leaf-name.  This is useful for
1827 dnl example with FreeBSD ports, which use this convention to distinguish
1828 dnl different versions of the same port.
1829 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1830         CF_SUBDIR_PATH(cf_search,$1,lib)
1831         for cf_item in $cf_search
1832         do
1833                 case $cf_item in
1834                 (*/$1)
1835                         CF_ADD_LIBDIR($cf_item)
1836                         ;;
1837                 esac
1838         done
1839 ])dnl
1840 dnl ---------------------------------------------------------------------------
1841 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1842 dnl -----------------
1843 dnl make ADAFLAGS consistent with CFLAGS
1844 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1845         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1846         case "$CFLAGS" in
1847         (*-g*)
1848                 CF_ADD_ADAFLAGS(-g)
1849                 ;;
1850         esac
1851         case "$CFLAGS" in
1852         (*-O*)
1853                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1854                 CF_ADD_ADAFLAGS($cf_O_flag)
1855                 ;;
1856         esac
1857         AC_MSG_RESULT($ADAFLAGS)
1858 ])dnl
1859 dnl ---------------------------------------------------------------------------
1860 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1861 dnl --------------
1862 dnl Forget that we saw the given tool.
1863 AC_DEFUN([CF_FORGET_TOOL],[
1864 unset ac_cv_prog_ac_ct_$1
1865 unset ac_ct_$1
1866 unset $1
1867 ])dnl
1868 dnl ---------------------------------------------------------------------------
1869 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
1870 dnl -------------
1871 dnl Test for dlsym() and related functions, as well as libdl.
1872 dnl
1873 dnl Sets
1874 dnl     $cf_have_dlsym
1875 dnl     $cf_have_libdl
1876 AC_DEFUN([CF_FUNC_DLSYM],[
1877 cf_have_dlsym=no
1878 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1879
1880 cf_have_libdl=no
1881 AC_CHECK_LIB(dl,dlsym,[
1882         cf_have_dlsym=yes
1883         cf_have_libdl=yes])])
1884
1885 if test "$cf_have_dlsym" = yes ; then
1886         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
1887
1888         AC_MSG_CHECKING(whether able to link to dl*() functions)
1889         AC_TRY_LINK([#include <dlfcn.h>],[
1890                 void *obj;
1891                 if ((obj = dlopen("filename", 0)) != 0) {
1892                         if (dlsym(obj, "symbolname") == 0) {
1893                         dlclose(obj);
1894                         }
1895                 }],[
1896                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1897                 AC_MSG_ERROR(Cannot link test program for libdl)])
1898         AC_MSG_RESULT(ok)
1899 else
1900         AC_MSG_ERROR(Cannot find dlsym function)
1901 fi
1902 ])
1903 dnl ---------------------------------------------------------------------------
1904 dnl CF_FUNC_MEMMOVE version: 8 updated: 2012/10/04 20:12:20
1905 dnl ---------------
1906 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1907 dnl is found, add our own version of memmove to the list of objects.
1908 AC_DEFUN([CF_FUNC_MEMMOVE],
1909 [
1910 AC_CHECK_FUNC(memmove,,[
1911 AC_CHECK_FUNC(bcopy,[
1912         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1913                 AC_TRY_RUN([
1914 int main() {
1915         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1916         char temp[40];
1917         bcopy(data, temp, sizeof(data));
1918         bcopy(temp+10, temp, 15);
1919         bcopy(temp+5, temp+15, 10);
1920         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1921 }
1922                 ],
1923                 [cf_cv_good_bcopy=yes],
1924                 [cf_cv_good_bcopy=no],
1925                 [cf_cv_good_bcopy=unknown])
1926                 ])
1927         ],[cf_cv_good_bcopy=no])
1928         if test "$cf_cv_good_bcopy" = yes ; then
1929                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1930         else
1931                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1932         fi
1933 ])])dnl
1934 dnl ---------------------------------------------------------------------------
1935 dnl CF_FUNC_NANOSLEEP version: 4 updated: 2012/10/06 17:56:13
1936 dnl -----------------
1937 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1938 dnl AIX 4.x, provide a non-working version.
1939 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1940 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1941 AC_TRY_RUN([
1942 #include <stdio.h>
1943 #include <errno.h>
1944 #include <time.h>
1945
1946 #ifdef HAVE_SYS_TIME_H
1947 #include <sys/time.h>
1948 #endif
1949
1950 int main() {
1951         struct timespec ts1, ts2;
1952         int code;
1953         ts1.tv_sec  = 0;
1954         ts1.tv_nsec = 750000000;
1955         ts2.tv_sec  = 0;
1956         ts2.tv_nsec = 0;
1957         errno = 0;
1958         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1959         ${cf_cv_main_return:-return}(code != 0);
1960 }
1961 ],
1962         [cf_cv_func_nanosleep=yes],
1963         [cf_cv_func_nanosleep=no],
1964         [cf_cv_func_nanosleep=unknown])])
1965
1966 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1967 ])
1968 dnl ---------------------------------------------------------------------------
1969 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
1970 dnl ---------------
1971 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1972 dnl "util" library as well.
1973 AC_DEFUN([CF_FUNC_OPENPTY],
1974 [
1975 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1976 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1977         cf_save_LIBS="$LIBS"
1978         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
1979         for cf_header in pty.h libutil.h util.h
1980         do
1981         AC_TRY_LINK([
1982 #include <$cf_header>
1983 ],[
1984         int x = openpty((int *)0, (int *)0, (char *)0,
1985                                    (struct termios *)0, (struct winsize *)0);
1986 ],[
1987                 cf_cv_func_openpty=$cf_header
1988                 break
1989 ],[
1990                 cf_cv_func_openpty=no
1991 ])
1992         done
1993         LIBS="$cf_save_LIBS"
1994 ])
1995 ])dnl
1996 dnl ---------------------------------------------------------------------------
1997 dnl CF_FUNC_POLL version: 9 updated: 2015/10/10 13:27:32
1998 dnl ------------
1999 dnl See if the poll function really works.  Some platforms have poll(), but
2000 dnl it does not work for terminals or files.
2001 AC_DEFUN([CF_FUNC_POLL],[
2002 tty 2>&1 >/dev/null || { AC_CHECK_FUNCS(posix_openpt) }
2003 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2004 AC_TRY_RUN([
2005 #include <stdlib.h>
2006 #include <stdio.h>
2007 #include <unistd.h>
2008 #include <fcntl.h>
2009 #ifdef HAVE_POLL_H
2010 #include <poll.h>
2011 #else
2012 #include <sys/poll.h>
2013 #endif
2014 int main(void) {
2015         struct pollfd myfds;
2016         int ret;
2017
2018         /* check for Darwin bug with respect to "devices" */
2019         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2020         if (myfds.fd < 0)
2021                 myfds.fd = 0;
2022         myfds.events = POLLIN;
2023         myfds.revents = 0;
2024
2025         ret = poll(&myfds, 1, 100);
2026
2027         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2028                 ret = -1;
2029         } else {
2030                 int fd = 0;
2031                 if (!isatty(fd)) {
2032                         fd = open("/dev/tty", 2);       /* O_RDWR */
2033                 }
2034 #ifdef HAVE_POSIX_OPENPT
2035                 if (fd < 0) {
2036                         fd = posix_openpt(O_RDWR);
2037                 }
2038 #endif
2039
2040                 if (fd >= 0) {
2041                         /* also check with standard input */
2042                         myfds.fd = fd;
2043                         myfds.events = POLLIN;
2044                         myfds.revents = 0;
2045                         ret = poll(&myfds, 1, 100);
2046                 } else {
2047                         ret = -1;
2048                 }
2049         }
2050         ${cf_cv_main_return:-return}(ret < 0);
2051 }],
2052         [cf_cv_working_poll=yes],
2053         [cf_cv_working_poll=no],
2054         [cf_cv_working_poll=unknown])])
2055 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2056 ])dnl
2057 dnl ---------------------------------------------------------------------------
2058 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2059 dnl ---------------
2060 dnl Some old/broken variations define tcgetattr() only as a macro in
2061 dnl termio(s).h
2062 AC_DEFUN([CF_FUNC_TERMIOS],[
2063 AC_REQUIRE([CF_STRUCT_TERMIOS])
2064 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2065 AC_TRY_LINK([
2066 #include <sys/types.h>
2067 #ifdef HAVE_UNISTD_H
2068 #include <unistd.h>
2069 #endif
2070 #ifdef HAVE_TERMIOS_H
2071 #include <termios.h>
2072 #define TTY struct termios
2073 #else
2074 #ifdef HAVE_TERMIO_H
2075 #include <termio.h>
2076 #define TTY struct termio
2077 #endif
2078 #endif
2079 ],[
2080 TTY foo;
2081 tcgetattr(1, &foo);],
2082 [cf_cv_have_tcgetattr=yes],
2083 [cf_cv_have_tcgetattr=no])])
2084 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2085 ])dnl
2086 dnl ---------------------------------------------------------------------------
2087 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
2088 dnl ---------------
2089 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2090 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2091 dnl other functions.
2092 AC_DEFUN([CF_FUNC_VSSCANF],
2093 [
2094 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2095 AC_TRY_LINK([
2096 #include <stdarg.h>
2097 #include <stdio.h>],[
2098         va_list ap;
2099         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2100 AC_TRY_LINK([
2101 #include <stdarg.h>
2102 #include <stdio.h>],[
2103         FILE strbuf;
2104         char *str = "from";
2105
2106         strbuf._flag = _IOREAD;
2107         strbuf._ptr = strbuf._base = (unsigned char *) str;
2108         strbuf._cnt = strlen(str);
2109         strbuf._file = _NFILE;
2110         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2111 AC_TRY_LINK([
2112 #include <stdarg.h>
2113 #include <stdio.h>],[
2114         FILE strbuf;
2115         char *str = "from";
2116
2117         strbuf._flag = _IOREAD;
2118         strbuf._ptr = strbuf._base = (unsigned char *) str;
2119         strbuf._cnt = strlen(str);
2120         strbuf._file = _NFILE;
2121         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2122 cf_cv_func_vsscanf=no])])])])
2123
2124 case $cf_cv_func_vsscanf in
2125 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2126 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2127 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2128 esac
2129
2130 ])dnl
2131 dnl ---------------------------------------------------------------------------
2132 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
2133 dnl -----------------
2134 dnl Test for availability of useful gcc __attribute__ directives to quiet
2135 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2136 dnl to documentation, unrecognized directives cause older compilers to barf.
2137 AC_DEFUN([CF_GCC_ATTRIBUTES],
2138 [
2139 if test "$GCC" = yes
2140 then
2141 cat > conftest.i <<EOF
2142 #ifndef GCC_PRINTF
2143 #define GCC_PRINTF 0
2144 #endif
2145 #ifndef GCC_SCANF
2146 #define GCC_SCANF 0
2147 #endif
2148 #ifndef GCC_NORETURN
2149 #define GCC_NORETURN /* nothing */
2150 #endif
2151 #ifndef GCC_UNUSED
2152 #define GCC_UNUSED /* nothing */
2153 #endif
2154 EOF
2155 if test "$GCC" = yes
2156 then
2157         AC_CHECKING([for $CC __attribute__ directives])
2158 cat > conftest.$ac_ext <<EOF
2159 #line __oline__ "${as_me:-configure}"
2160 #include "confdefs.h"
2161 #include "conftest.h"
2162 #include "conftest.i"
2163 #if     GCC_PRINTF
2164 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2165 #else
2166 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2167 #endif
2168 #if     GCC_SCANF
2169 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2170 #else
2171 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2172 #endif
2173 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2174 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
2175 extern void foo(void) GCC_NORETURN;
2176 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
2177 EOF
2178         cf_printf_attribute=no
2179         cf_scanf_attribute=no
2180         for cf_attribute in scanf printf unused noreturn
2181         do
2182                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2183                 cf_directive="__attribute__(($cf_attribute))"
2184                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2185
2186                 case $cf_attribute in
2187                 (printf)
2188                         cf_printf_attribute=yes
2189                         cat >conftest.h <<EOF
2190 #define GCC_$cf_ATTRIBUTE 1
2191 EOF
2192                         ;;
2193                 (scanf)
2194                         cf_scanf_attribute=yes
2195                         cat >conftest.h <<EOF
2196 #define GCC_$cf_ATTRIBUTE 1
2197 EOF
2198                         ;;
2199                 (*)
2200                         cat >conftest.h <<EOF
2201 #define GCC_$cf_ATTRIBUTE $cf_directive
2202 EOF
2203                         ;;
2204                 esac
2205
2206                 if AC_TRY_EVAL(ac_compile); then
2207                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2208                         cat conftest.h >>confdefs.h
2209                         case $cf_attribute in
2210                         (noreturn)
2211                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2212                                 ;;
2213                         (printf)
2214                                 cf_value='/* nothing */'
2215                                 if test "$cf_printf_attribute" != no ; then
2216                                         cf_value='__attribute__((format(printf,fmt,var)))'
2217                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2218                                 fi
2219                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2220                                 ;;
2221                         (scanf)
2222                                 cf_value='/* nothing */'
2223                                 if test "$cf_scanf_attribute" != no ; then
2224                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2225                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2226                                 fi
2227                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2228                                 ;;
2229                         (unused)
2230                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2231                                 ;;
2232                         esac
2233                 fi
2234         done
2235 else
2236         fgrep define conftest.i >>confdefs.h
2237 fi
2238 rm -rf conftest*
2239 fi
2240 ])dnl
2241 dnl ---------------------------------------------------------------------------
2242 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
2243 dnl --------------
2244 dnl Find version of gcc
2245 AC_DEFUN([CF_GCC_VERSION],[
2246 AC_REQUIRE([AC_PROG_CC])
2247 GCC_VERSION=none
2248 if test "$GCC" = yes ; then
2249         AC_MSG_CHECKING(version of $CC)
2250         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2251         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2252         AC_MSG_RESULT($GCC_VERSION)
2253 fi
2254 ])dnl
2255 dnl ---------------------------------------------------------------------------
2256 dnl CF_GCC_WARNINGS version: 32 updated: 2015/04/12 15:39:00
2257 dnl ---------------
2258 dnl Check if the compiler supports useful warning options.  There's a few that
2259 dnl we don't use, simply because they're too noisy:
2260 dnl
2261 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2262 dnl     -Wredundant-decls (system headers make this too noisy)
2263 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2264 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2265 dnl             is enabled for ncurses using "--enable-const".
2266 dnl     -pedantic
2267 dnl
2268 dnl Parameter:
2269 dnl     $1 is an optional list of gcc warning flags that a particular
2270 dnl             application might want to use, e.g., "no-unused" for
2271 dnl             -Wno-unused
2272 dnl Special:
2273 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2274 dnl
2275 AC_DEFUN([CF_GCC_WARNINGS],
2276 [
2277 AC_REQUIRE([CF_GCC_VERSION])
2278 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2279 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2280
2281 cat > conftest.$ac_ext <<EOF
2282 #line __oline__ "${as_me:-configure}"
2283 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2284 EOF
2285
2286 if test "$INTEL_COMPILER" = yes
2287 then
2288 # The "-wdXXX" options suppress warnings:
2289 # remark #1419: external declaration in primary source file
2290 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2291 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2292 # remark #193: zero used for undefined preprocessing identifier
2293 # remark #593: variable "curs_sb_left_arrow" was set but never used
2294 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2295 # remark #869: parameter "tw" was never referenced
2296 # remark #981: operands are evaluated in unspecified order
2297 # warning #279: controlling expression is constant
2298
2299         AC_CHECKING([for $CC warning options])
2300         cf_save_CFLAGS="$CFLAGS"
2301         EXTRA_CFLAGS="-Wall"
2302         for cf_opt in \
2303                 wd1419 \
2304                 wd1683 \
2305                 wd1684 \
2306                 wd193 \
2307                 wd593 \
2308                 wd279 \
2309                 wd810 \
2310                 wd869 \
2311                 wd981
2312         do
2313                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2314                 if AC_TRY_EVAL(ac_compile); then
2315                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2316                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2317                 fi
2318         done
2319         CFLAGS="$cf_save_CFLAGS"
2320
2321 elif test "$GCC" = yes
2322 then
2323         AC_CHECKING([for $CC warning options])
2324         cf_save_CFLAGS="$CFLAGS"
2325         EXTRA_CFLAGS=
2326         cf_warn_CONST=""
2327         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2328         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2329         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2330         for cf_opt in W Wall \
2331                 Wbad-function-cast \
2332                 Wcast-align \
2333                 Wcast-qual \
2334                 Wdeclaration-after-statement \
2335                 Wextra \
2336                 Winline \
2337                 Wmissing-declarations \
2338                 Wmissing-prototypes \
2339                 Wnested-externs \
2340                 Wpointer-arith \
2341                 Wshadow \
2342                 Wstrict-prototypes \
2343                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2344         do
2345                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2346                 if AC_TRY_EVAL(ac_compile); then
2347                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2348                         case $cf_opt in
2349                         (Wcast-qual)
2350                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2351                                 ;;
2352                         (Winline)
2353                                 case $GCC_VERSION in
2354                                 ([[34]].*)
2355                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2356                                         continue;;
2357                                 esac
2358                                 ;;
2359                         (Wpointer-arith)
2360                                 case $GCC_VERSION in
2361                                 ([[12]].*)
2362                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2363                                         continue;;
2364                                 esac
2365                                 ;;
2366                         esac
2367                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2368                 fi
2369         done
2370         CFLAGS="$cf_save_CFLAGS"
2371 fi
2372 rm -rf conftest*
2373
2374 AC_SUBST(EXTRA_CFLAGS)
2375 ])dnl
2376 dnl ---------------------------------------------------------------------------
2377 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2378 dnl ----------------
2379 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2380 dnl unistd.h or (nonstandard) in getopt.h
2381 AC_DEFUN([CF_GETOPT_HEADER],
2382 [
2383 AC_HAVE_HEADERS(unistd.h getopt.h)
2384 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2385 cf_cv_getopt_header=none
2386 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2387 do
2388 AC_TRY_COMPILE([
2389 #include <$cf_header>],
2390 [int x = optind; char *y = optarg],
2391 [cf_cv_getopt_header=$cf_header
2392  break])
2393 done
2394 ])
2395 if test $cf_cv_getopt_header != none ; then
2396         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2397 fi
2398 if test $cf_cv_getopt_header = getopt.h ; then
2399         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2400 fi
2401 ])dnl
2402 dnl ---------------------------------------------------------------------------
2403 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2404 dnl -----------------
2405 AC_DEFUN([CF_GNATPREP_OPT_T],[
2406 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2407 cf_cv_gnatprep_opt_t=no
2408 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2409 ])
2410 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2411 AC_SUBST(GNATPREP_OPTS)
2412 ])dnl
2413 dnl ---------------------------------------------------------------------------
2414 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
2415 dnl ----------------
2416 AC_DEFUN([CF_GNAT_GENERICS],
2417 [
2418 AC_REQUIRE([CF_GNAT_VERSION])
2419
2420 AC_MSG_CHECKING(if GNAT supports generics)
2421 case $cf_gnat_version in
2422 (3.[[1-9]]*|[[4-9]].*)
2423         cf_gnat_generics=yes
2424         ;;
2425 (*)
2426         cf_gnat_generics=no
2427         ;;
2428 esac
2429 AC_MSG_RESULT($cf_gnat_generics)
2430
2431 if test "$cf_gnat_generics" = yes
2432 then
2433         cf_compile_generics=generics
2434         cf_generic_objects="\${GENOBJS}"
2435 else
2436         cf_compile_generics=
2437         cf_generic_objects=
2438 fi
2439
2440 AC_SUBST(cf_compile_generics)
2441 AC_SUBST(cf_generic_objects)
2442 ])dnl
2443 dnl ---------------------------------------------------------------------------
2444 dnl CF_GNAT_PROJECTS version: 8 updated: 2015/04/17 21:13:04
2445 dnl ----------------
2446 dnl GNAT projects are configured with ".gpr" project files.
2447 dnl GNAT libraries are a further development, using the project feature.
2448 AC_DEFUN([CF_GNAT_PROJECTS],
2449 [
2450 AC_REQUIRE([CF_GNAT_VERSION])
2451 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2452
2453 cf_gnat_libraries=no
2454 cf_gnat_projects=no
2455
2456 if test "$enable_gnat_projects" != no ; then
2457 AC_MSG_CHECKING(if GNAT supports project files)
2458 case $cf_gnat_version in
2459 (3.[[0-9]]*)
2460         ;;
2461 (*)
2462         case $cf_cv_system_name in
2463         (cygwin*|msys*)
2464                 ;;
2465         (*)
2466                 mkdir conftest.src conftest.bin conftest.lib
2467                 cd conftest.src
2468                 rm -rf conftest* *~conftest*
2469                 cat >>library.gpr <<CF_EOF
2470 project Library is
2471   Kind := External ("LIB_KIND");
2472   for Library_Name use "ConfTest";
2473   for Object_Dir use ".";
2474   for Library_ALI_Dir use External("LIBRARY_DIR");
2475   for Library_Version use External ("SONAME");
2476   for Library_Kind use Kind;
2477   for Library_Dir use External("BUILD_DIR");
2478   Source_Dir := External ("SOURCE_DIR");
2479   for Source_Dirs use (Source_Dir);
2480 end Library;
2481 CF_EOF
2482                 cat >>confpackage.ads <<CF_EOF
2483 package ConfPackage is
2484    procedure conftest;
2485 end ConfPackage;
2486 CF_EOF
2487                 cat >>confpackage.adb <<CF_EOF
2488 with Text_IO;
2489 package body ConfPackage is
2490    procedure conftest is
2491    begin
2492       Text_IO.Put ("Hello World");
2493       Text_IO.New_Line;
2494    end conftest;
2495 end ConfPackage;
2496 CF_EOF
2497                 if ( $cf_ada_make $ADAFLAGS \
2498                                 -Plibrary.gpr \
2499                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2500                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2501                                 -XSOURCE_DIR=`pwd` \
2502                                 -XSONAME=libConfTest.so.1 \
2503                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2504                         cf_gnat_projects=yes
2505                 fi
2506                 cd ..
2507                 if test -f conftest.lib/confpackage.ali
2508                 then
2509                         cf_gnat_libraries=yes
2510                 fi
2511                 rm -rf conftest* *~conftest*
2512                 ;;
2513         esac
2514         ;;
2515 esac
2516 AC_MSG_RESULT($cf_gnat_projects)
2517 fi # enable_gnat_projects
2518
2519 if test $cf_gnat_projects = yes
2520 then
2521         AC_MSG_CHECKING(if GNAT supports libraries)
2522         AC_MSG_RESULT($cf_gnat_libraries)
2523 fi
2524
2525 if test "$cf_gnat_projects" = yes
2526 then
2527         USE_OLD_MAKERULES="#"
2528         USE_GNAT_PROJECTS=""
2529 else
2530         USE_OLD_MAKERULES=""
2531         USE_GNAT_PROJECTS="#"
2532 fi
2533
2534 if test "$cf_gnat_libraries" = yes
2535 then
2536         USE_GNAT_LIBRARIES=""
2537 else
2538         USE_GNAT_LIBRARIES="#"
2539 fi
2540
2541 AC_SUBST(USE_OLD_MAKERULES)
2542 AC_SUBST(USE_GNAT_PROJECTS)
2543 AC_SUBST(USE_GNAT_LIBRARIES)
2544 ])dnl
2545 dnl ---------------------------------------------------------------------------
2546 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2547 dnl --------------
2548 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2549 dnl is noted that gnat may compile a tasking unit even for configurations which
2550 dnl fail at runtime.
2551 AC_DEFUN([CF_GNAT_SIGINT],[
2552 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2553 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2554
2555 package ConfTest is
2556
2557    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2558    pragma Unreserve_All_Interrupts;
2559    pragma Warnings (On);
2560
2561    protected Process is
2562       procedure Stop;
2563       function Continue return Boolean;
2564       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2565    private
2566       Done : Boolean := False;
2567    end Process;
2568
2569 end ConfTest;],
2570 [package body ConfTest is
2571    protected body Process is
2572       procedure Stop is
2573       begin
2574          Done := True;
2575       end Stop;
2576       function Continue return Boolean is
2577       begin
2578          return not Done;
2579       end Continue;
2580    end Process;
2581 end ConfTest;],
2582         [cf_cv_gnat_sigint=yes],
2583         [cf_cv_gnat_sigint=no])])
2584
2585 if test $cf_cv_gnat_sigint = yes ; then
2586         USE_GNAT_SIGINT=""
2587 else
2588         USE_GNAT_SIGINT="#"
2589 fi
2590 AC_SUBST(USE_GNAT_SIGINT)
2591 ])dnl
2592 dnl ---------------------------------------------------------------------------
2593 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2594 dnl ----------------
2595 dnl Verify that a test program compiles/links with GNAT.
2596 dnl $cf_ada_make is set to the program that compiles/links
2597 dnl $ADAFLAGS may be set to the GNAT flags.
2598 dnl
2599 dnl $1 is the text of the spec
2600 dnl $2 is the text of the body
2601 dnl $3 is the shell command to execute if successful
2602 dnl $4 is the shell command to execute if not successful
2603 AC_DEFUN([CF_GNAT_TRY_LINK],
2604 [
2605 rm -rf conftest* *~conftest*
2606 cat >>conftest.ads <<CF_EOF
2607 $1
2608 CF_EOF
2609 cat >>conftest.adb <<CF_EOF
2610 $2
2611 CF_EOF
2612 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2613 ifelse($3,,      :,[      $3])
2614 ifelse($4,,,[else
2615    $4])
2616 fi
2617 rm -rf conftest* *~conftest*
2618 ])dnl
2619 dnl ---------------------------------------------------------------------------
2620 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2621 dnl ---------------
2622 dnl Verify that a test program compiles and runs with GNAT
2623 dnl $cf_ada_make is set to the program that compiles/links
2624 dnl $ADAFLAGS may be set to the GNAT flags.
2625 dnl
2626 dnl $1 is the text of the spec
2627 dnl $2 is the text of the body
2628 dnl $3 is the shell command to execute if successful
2629 dnl $4 is the shell command to execute if not successful
2630 AC_DEFUN([CF_GNAT_TRY_RUN],
2631 [
2632 rm -rf conftest* *~conftest*
2633 cat >>conftest.ads <<CF_EOF
2634 $1
2635 CF_EOF
2636 cat >>conftest.adb <<CF_EOF
2637 $2
2638 CF_EOF
2639 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2640    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2641 ifelse($3,,      :,[      $3])
2642 ifelse($4,,,[   else
2643       $4])
2644    fi
2645 ifelse($4,,,[else
2646    $4])
2647 fi
2648 rm -rf conftest* *~conftest*
2649 ])dnl
2650 dnl ---------------------------------------------------------------------------
2651 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
2652 dnl ---------------
2653 dnl Verify version of GNAT.
2654 AC_DEFUN([CF_GNAT_VERSION],
2655 [
2656 AC_MSG_CHECKING(for gnat version)
2657 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2658         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2659         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2660 AC_MSG_RESULT($cf_gnat_version)
2661
2662 case $cf_gnat_version in
2663 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
2664         cf_cv_prog_gnat_correct=yes
2665         ;;
2666 (*)
2667         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2668         cf_cv_prog_gnat_correct=no
2669         ;;
2670 esac
2671 ])
2672 dnl ---------------------------------------------------------------------------
2673 dnl CF_GNU_SOURCE version: 7 updated: 2016/08/05 05:15:37
2674 dnl -------------
2675 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2676 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2677 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2678 dnl since it is interwoven with GNU extensions.
2679 dnl
2680 dnl Well, yes we could work around it...
2681 AC_DEFUN([CF_GNU_SOURCE],
2682 [
2683 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2684 AC_TRY_COMPILE([#include <sys/types.h>],[
2685 #ifndef _XOPEN_SOURCE
2686 make an error
2687 #endif],
2688         [cf_cv_gnu_source=no],
2689         [cf_save="$CPPFLAGS"
2690          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2691          AC_TRY_COMPILE([#include <sys/types.h>],[
2692 #ifdef _XOPEN_SOURCE
2693 make an error
2694 #endif],
2695         [cf_cv_gnu_source=no],
2696         [cf_cv_gnu_source=yes])
2697         CPPFLAGS="$cf_save"
2698         ])
2699 ])
2700
2701 if test "$cf_cv_gnu_source" = yes
2702 then
2703 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
2704 CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2705         AC_TRY_COMPILE([#include <sys/types.h>],[
2706 #ifdef _DEFAULT_SOURCE
2707 make an error
2708 #endif],
2709                 [cf_cv_default_source=no],
2710                 [cf_cv_default_source=yes])
2711         ])
2712 test "$cf_cv_default_source" = yes && CPPFLAGS="$CPPFLAGS -D_DEFAULT_SOURCE"
2713 fi
2714 ])dnl
2715 dnl ---------------------------------------------------------------------------
2716 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
2717 dnl --------------
2718 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2719 dnl problem :-).  If we have the compiler but no library, we'll be able to
2720 dnl configure, but won't be able to build the c++ demo program.
2721 AC_DEFUN([CF_GPP_LIBRARY],
2722 [
2723 cf_cxx_library=unknown
2724 case $cf_cv_system_name in
2725 (os2*)
2726         cf_gpp_libname=gpp
2727         ;;
2728 (*)
2729         cf_gpp_libname=g++
2730         ;;
2731 esac
2732 if test "$GXX" = yes; then
2733         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2734         cf_save="$LIBS"
2735         CF_ADD_LIB($cf_gpp_libname)
2736         AC_TRY_LINK([
2737 #include <$cf_gpp_libname/builtin.h>
2738         ],
2739         [two_arg_error_handler_t foo2 = lib_error_handler],
2740         [cf_cxx_library=yes
2741          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2742          if test "$cf_gpp_libname" = cpp ; then
2743             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2744          else
2745             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2746          fi],
2747         [AC_TRY_LINK([
2748 #include <builtin.h>
2749         ],
2750         [two_arg_error_handler_t foo2 = lib_error_handler],
2751         [cf_cxx_library=yes
2752          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2753          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2754         [cf_cxx_library=no])])
2755         LIBS="$cf_save"
2756         AC_MSG_RESULT($cf_cxx_library)
2757 fi
2758 ])dnl
2759 dnl ---------------------------------------------------------------------------
2760 dnl CF_GXX_VERSION version: 7 updated: 2012/06/16 14:55:39
2761 dnl --------------
2762 dnl Check for version of g++
2763 AC_DEFUN([CF_GXX_VERSION],[
2764 AC_REQUIRE([AC_PROG_CPP])
2765 GXX_VERSION=none
2766 if test "$GXX" = yes; then
2767         AC_MSG_CHECKING(version of ${CXX:-g++})
2768         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2769         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2770         AC_MSG_RESULT($GXX_VERSION)
2771 fi
2772 ])dnl
2773 dnl ---------------------------------------------------------------------------
2774 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
2775 dnl ---------------
2776 dnl Check if the compiler supports useful warning options.
2777 dnl
2778 dnl Most of gcc's options apply to g++, except:
2779 dnl     -Wbad-function-cast
2780 dnl     -Wmissing-declarations
2781 dnl     -Wnested-externs
2782 dnl
2783 dnl Omit a few (for now):
2784 dnl     -Winline
2785 dnl
2786 dnl Parameter:
2787 dnl     $1 is an optional list of g++ warning flags that a particular
2788 dnl             application might want to use, e.g., "no-unused" for
2789 dnl             -Wno-unused
2790 dnl Special:
2791 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2792 dnl
2793 AC_DEFUN([CF_GXX_WARNINGS],
2794 [
2795
2796 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2797 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2798
2799 AC_REQUIRE([CF_GXX_VERSION])
2800
2801 AC_LANG_SAVE
2802 AC_LANG_CPLUSPLUS
2803
2804 cat > conftest.$ac_ext <<EOF
2805 #line __oline__ "configure"
2806 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2807 EOF
2808
2809 if test "$INTEL_CPLUSPLUS" = yes
2810 then
2811 # The "-wdXXX" options suppress warnings:
2812 # remark #1419: external declaration in primary source file
2813 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2814 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2815 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2816 # remark #193: zero used for undefined preprocessing identifier
2817 # remark #593: variable "curs_sb_left_arrow" was set but never used
2818 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2819 # remark #869: parameter "tw" was never referenced
2820 # remark #981: operands are evaluated in unspecified order
2821 # warning #269: invalid format string conversion
2822
2823         AC_CHECKING([for $CC warning options])
2824         cf_save_CXXFLAGS="$CXXFLAGS"
2825         EXTRA_CXXFLAGS="-Wall"
2826         for cf_opt in \
2827                 wd1419 \
2828                 wd1682 \
2829                 wd1683 \
2830                 wd1684 \
2831                 wd193 \
2832                 wd279 \
2833                 wd593 \
2834                 wd810 \
2835                 wd869 \
2836                 wd981
2837         do
2838                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2839                 if AC_TRY_EVAL(ac_compile); then
2840                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2841                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2842                 fi
2843         done
2844         CXXFLAGS="$cf_save_CXXFLAGS"
2845
2846 elif test "$GXX" = yes
2847 then
2848         AC_CHECKING([for $CXX warning options])
2849         cf_save_CXXFLAGS="$CXXFLAGS"
2850         EXTRA_CXXFLAGS="-W -Wall"
2851         cf_gxx_extra_warnings=""
2852         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2853         case "$GCC_VERSION" in
2854         ([[1-2]].*)
2855                 ;;
2856         (*)
2857                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2858                 ;;
2859         esac
2860         for cf_opt in \
2861                 Wabi \
2862                 fabi-version=0 \
2863                 Wextra \
2864                 Wignored-qualifiers \
2865                 Wlogical-op \
2866                 Woverloaded-virtual \
2867                 Wsign-promo \
2868                 Wsynth \
2869                 Wold-style-cast \
2870                 Wcast-align \
2871                 Wcast-qual \
2872                 Wpointer-arith \
2873                 Wshadow \
2874                 Wundef $cf_gxx_extra_warnings $1
2875         do
2876                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2877                 if AC_TRY_EVAL(ac_compile); then
2878                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2879                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2880                 else
2881                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2882                 fi
2883         done
2884         CXXFLAGS="$cf_save_CXXFLAGS"
2885 fi
2886
2887 rm -rf conftest*
2888 AC_LANG_RESTORE
2889 AC_SUBST(EXTRA_CXXFLAGS)
2890 ])dnl
2891 dnl ---------------------------------------------------------------------------
2892 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
2893 dnl ------------
2894 dnl Look for an instance of the Berkeley hashed database.
2895 dnl
2896 dnl $1 = optional parameter, to specify install-prefix for the database.
2897 AC_DEFUN([CF_HASHED_DB],
2898 [
2899 ifelse([$1],,,[
2900 case $1 in
2901 (yes|*able*)
2902         ;;
2903 (*)
2904         if test -d "$1" ; then
2905                 CF_ADD_INCDIR($1/include)
2906                 CF_ADD_LIBDIR($1/lib)
2907         else
2908                 case "$1" in
2909                 (./*|../*|/*)
2910                         AC_MSG_WARN(no such directory $1)
2911                         ;;
2912                 (*)
2913                         CF_FIND_SUB_INCDIR($1)
2914                         CF_FIND_SUB_LIBDIR($1)
2915                         ;;
2916                 esac
2917         fi
2918 esac
2919 ])
2920 AC_CHECK_HEADER(db.h,[
2921 CF_HASHED_DB_VERSION
2922 if test "$cf_cv_hashed_db_version" = unknown ; then
2923         AC_MSG_ERROR(Cannot determine version of db)
2924 else
2925         CF_HASHED_DB_LIBS
2926         if test "$cf_cv_hashed_db_libs" = unknown ; then
2927                 AC_MSG_ERROR(Cannot determine library for db)
2928         elif test "$cf_cv_hashed_db_libs" != default ; then
2929                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2930         fi
2931 fi
2932 ],[
2933         AC_MSG_ERROR(Cannot find db.h)
2934 ])
2935 ])dnl
2936 dnl ---------------------------------------------------------------------------
2937 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2938 dnl -----------------
2939 dnl Given that we have the header and version for hashed database, find the
2940 dnl library information.
2941 AC_DEFUN([CF_HASHED_DB_LIBS],
2942 [
2943 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2944 cf_cv_hashed_db_libs=unknown
2945 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2946 do
2947         cf_save_libs="$LIBS"
2948         if test -n "$cf_db_libs"; then
2949                 CF_ADD_LIB($cf_db_libs)
2950         fi
2951         CF_MSG_LOG(checking for library "$cf_db_libs")
2952         AC_TRY_LINK([
2953 $ac_includes_default
2954 #include <db.h>
2955 ],[
2956         char *path = "/tmp/foo";
2957 #ifdef DB_VERSION_MAJOR
2958 #if DB_VERSION_MAJOR >= 4
2959         DB *result = 0;
2960         db_create(&result, NULL, 0);
2961         result->open(result,
2962                 NULL,
2963                 path,
2964                 path,
2965                 DB_HASH,
2966                 DB_CREATE,
2967                 0644);
2968 #elif DB_VERSION_MAJOR >= 3
2969         DB *result = 0;
2970         db_create(&result, NULL, 0);
2971         result->open(result,
2972                 path,
2973                 path,
2974                 DB_HASH,
2975                 DB_CREATE,
2976                 0644);
2977 #elif DB_VERSION_MAJOR >= 2
2978         DB *result = 0;
2979         db_open(path,
2980                 DB_HASH,
2981                 DB_CREATE,
2982                 0644,
2983                 (DB_ENV *) 0,
2984                 (DB_INFO *) 0,
2985                 &result);
2986 #endif /* DB_VERSION_MAJOR */
2987 #else
2988         DB *result = dbopen(path,
2989                      2,
2990                      0644,
2991                      DB_HASH,
2992                      0);
2993 #endif
2994         ${cf_cv_main_return:-return}(result != 0)
2995 ],[
2996         if test -n "$cf_db_libs" ; then
2997                 cf_cv_hashed_db_libs=$cf_db_libs
2998         else
2999                 cf_cv_hashed_db_libs=default
3000         fi
3001         LIBS="$cf_save_libs"
3002         break
3003 ])
3004         LIBS="$cf_save_libs"
3005 done
3006 ])
3007 ])dnl
3008 dnl ---------------------------------------------------------------------------
3009 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3010 dnl --------------------
3011 dnl Given that we have the header file for hashed database, find the version
3012 dnl information.
3013 AC_DEFUN([CF_HASHED_DB_VERSION],
3014 [
3015 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3016 cf_cv_hashed_db_version=unknown
3017
3018 for cf_db_version in 1 2 3 4 5 6
3019 do
3020         CF_MSG_LOG(checking for db version $cf_db_version)
3021         AC_TRY_COMPILE([
3022 $ac_includes_default
3023 #include <db.h>
3024
3025 #ifdef DB_VERSION_MAJOR
3026         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3027 #if $cf_db_version == DB_VERSION_MAJOR
3028         /* ok */
3029 #else
3030         make an error
3031 #endif
3032 #else
3033 #if $cf_db_version == 1
3034         /* ok: assuming this is DB 1.8.5 */
3035 #else
3036         make an error
3037 #endif
3038 #endif
3039 ],[DBT *foo = 0],[
3040         cf_cv_hashed_db_version=$cf_db_version
3041         break
3042         ])
3043 done
3044 ])
3045 ])dnl
3046 dnl ---------------------------------------------------------------------------
3047 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
3048 dnl --------------
3049 dnl Construct a search-list of directories for a nonstandard header-file
3050 dnl
3051 dnl Parameters
3052 dnl     $1 = the variable to return as result
3053 dnl     $2 = the package name
3054 AC_DEFUN([CF_HEADER_PATH],
3055 [
3056 $1=
3057
3058 # collect the current set of include-directories from compiler flags
3059 cf_header_path_list=""
3060 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3061         for cf_header_path in $CPPFLAGS $CFLAGS
3062         do
3063                 case $cf_header_path in
3064                 (-I*)
3065                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3066                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3067                         cf_header_path_list="$cf_header_path_list [$]$1"
3068                         ;;
3069                 esac
3070         done
3071 fi
3072
3073 # add the variations for the package we are looking for
3074 CF_SUBDIR_PATH($1,$2,include)
3075
3076 test "$includedir" != NONE && \
3077 test "$includedir" != "/usr/include" && \
3078 test -d "$includedir" && {
3079         test -d $includedir &&    $1="[$]$1 $includedir"
3080         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
3081 }
3082
3083 test "$oldincludedir" != NONE && \
3084 test "$oldincludedir" != "/usr/include" && \
3085 test -d "$oldincludedir" && {
3086         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
3087         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
3088 }
3089
3090 $1="[$]$1 $cf_header_path_list"
3091 ])dnl
3092 dnl ---------------------------------------------------------------------------
3093 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
3094 dnl ---------------
3095 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3096 AC_DEFUN([CF_HELP_MESSAGE],
3097 [AC_DIVERT_HELP([$1])dnl
3098 ])dnl
3099 dnl ---------------------------------------------------------------------------
3100 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3101 dnl ---------------
3102 dnl Construct the list of include-options according to whether we're building
3103 dnl in the source directory or using '--srcdir=DIR' option.
3104 AC_DEFUN([CF_INCLUDE_DIRS],
3105 [
3106 if test "$srcdir" != "."; then
3107         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3108 fi
3109 CPPFLAGS="-I../include $CPPFLAGS"
3110 if test "$srcdir" != "."; then
3111         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3112 fi
3113 CPPFLAGS="-I. $CPPFLAGS"
3114 AC_SUBST(CPPFLAGS)
3115 ])dnl
3116 dnl ---------------------------------------------------------------------------
3117 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
3118 dnl -----------------
3119 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3120 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3121 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3122 dnl
3123 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3124 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3125 dnl the wrappers for gcc and g++ warnings.
3126 dnl
3127 dnl $1 = GCC (default) or GXX
3128 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3129 dnl $3 = CFLAGS (default) or CXXFLAGS
3130 AC_DEFUN([CF_INTEL_COMPILER],[
3131 AC_REQUIRE([AC_CANONICAL_HOST])
3132 ifelse([$2],,INTEL_COMPILER,[$2])=no
3133
3134 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3135         case $host_os in
3136         (linux*|gnu*)
3137                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3138                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3139                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3140                 AC_TRY_COMPILE([],[
3141 #ifdef __INTEL_COMPILER
3142 #else
3143 make an error
3144 #endif
3145 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3146 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3147 ],[])
3148                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3149                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3150                 ;;
3151         esac
3152 fi
3153 ])dnl
3154 dnl ---------------------------------------------------------------------------
3155 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3156 dnl ----------
3157 dnl Check if we have either a function or macro for 'isascii()'.
3158 AC_DEFUN([CF_ISASCII],
3159 [
3160 AC_MSG_CHECKING(for isascii)
3161 AC_CACHE_VAL(cf_cv_have_isascii,[
3162         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3163         [cf_cv_have_isascii=yes],
3164         [cf_cv_have_isascii=no])
3165 ])dnl
3166 AC_MSG_RESULT($cf_cv_have_isascii)
3167 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3168 ])dnl
3169 dnl ---------------------------------------------------------------------------
3170 dnl CF_LARGEFILE version: 9 updated: 2015/04/18 08:56:57
3171 dnl ------------
3172 dnl Add checks for large file support.
3173 AC_DEFUN([CF_LARGEFILE],[
3174 ifdef([AC_FUNC_FSEEKO],[
3175         AC_SYS_LARGEFILE
3176         if test "$enable_largefile" != no ; then
3177         AC_FUNC_FSEEKO
3178
3179         # Normally we would collect these definitions in the config.h,
3180         # but (like _XOPEN_SOURCE), some environments rely on having these
3181         # defined before any of the system headers are included.  Another
3182         # case comes up with C++, e.g., on AIX the compiler compiles the
3183         # header files by themselves before looking at the body files it is
3184         # told to compile.  For ncurses, those header files do not include
3185         # the config.h
3186         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
3187         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
3188         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
3189
3190         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3191                 AC_TRY_COMPILE([
3192 #include <sys/types.h>
3193 #include <dirent.h>
3194                 ],[
3195                 /* if transitional largefile support is setup, this is true */
3196                 extern struct dirent64 * readdir(DIR *);
3197                 struct dirent64 *x = readdir((DIR *)0);
3198                 struct dirent *y = readdir((DIR *)0);
3199                 int z = x - y;
3200                 ],
3201                 [cf_cv_struct_dirent64=yes],
3202                 [cf_cv_struct_dirent64=no])
3203         ])
3204         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3205         fi
3206 ])
3207 ])
3208 dnl ---------------------------------------------------------------------------
3209 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3210 dnl -----------------
3211 dnl Check for compiler/linker flags used to temporarily force usage of static
3212 dnl libraries.  This depends on the compiler and platform.  Use this to help
3213 dnl ensure that the linker picks up a given library based on its position in
3214 dnl the list of linker options and libraries.
3215 AC_DEFUN([CF_LDFLAGS_STATIC],[
3216
3217 if test "$GCC" = yes ; then
3218         case $cf_cv_system_name in
3219         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3220                 LDFLAGS_STATIC=
3221                 LDFLAGS_SHARED=
3222                 ;;
3223         (*)     # normally, except when broken
3224                 LDFLAGS_STATIC=-static
3225                 LDFLAGS_SHARED=-dynamic
3226                 ;;
3227         esac
3228 else
3229         case $cf_cv_system_name in
3230         (aix[[4-7]]*)   # from ld manpage
3231                 LDFLAGS_STATIC=-bstatic
3232                 LDFLAGS_SHARED=-bdynamic
3233                 ;;
3234         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3235                 # We could also use just "archive" and "shared".
3236                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3237                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3238                 ;;
3239         (irix*)         # from ld manpage IRIX64
3240                 LDFLAGS_STATIC=-Bstatic
3241                 LDFLAGS_SHARED=-Bdynamic
3242                 ;;
3243         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3244                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3245                 LDFLAGS_STATIC=-noso
3246                 LDFLAGS_SHARED=-so_archive
3247                 ;;
3248         (solaris2*)
3249                 LDFLAGS_STATIC=-Bstatic
3250                 LDFLAGS_SHARED=-Bdynamic
3251                 ;;
3252         esac
3253 fi
3254
3255 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3256 then
3257         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3258
3259         rm -f libconftest.a
3260         cat >conftest.$ac_ext <<EOF
3261 #line __oline__ "configure"
3262 #include <stdio.h>
3263 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3264 EOF
3265         if AC_TRY_EVAL(ac_compile) ; then
3266                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3267                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3268         fi
3269         rm -f conftest.*
3270
3271         cf_save_LIBS="$LIBS"
3272
3273         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3274         AC_TRY_LINK([
3275 #line __oline__ "configure"
3276 #include <stdio.h>
3277 int cf_ldflags_static(FILE *fp);
3278 ],[
3279         return cf_ldflags_static(stdin);
3280 ],[
3281         # some linkers simply ignore the -dynamic
3282         case x`file conftest$ac_exeext 2>/dev/null` in
3283         (*static*)
3284                 cf_ldflags_static=no
3285                 ;;
3286         (*)
3287                 cf_ldflags_static=yes
3288                 ;;
3289         esac
3290 ],[cf_ldflags_static=no])
3291
3292         rm -f libconftest.*
3293         LIBS="$cf_save_LIBS"
3294
3295         AC_MSG_RESULT($cf_ldflags_static)
3296
3297         if test $cf_ldflags_static != yes
3298         then
3299                 LDFLAGS_STATIC=
3300                 LDFLAGS_SHARED=
3301         fi
3302 else
3303         LDFLAGS_STATIC=
3304         LDFLAGS_SHARED=
3305 fi
3306
3307 AC_SUBST(LDFLAGS_STATIC)
3308 AC_SUBST(LDFLAGS_SHARED)
3309 ])
3310 dnl ---------------------------------------------------------------------------
3311 dnl CF_LD_RPATH_OPT version: 7 updated: 2016/02/20 18:01:19
3312 dnl ---------------
3313 dnl For the given system and compiler, find the compiler flags to pass to the
3314 dnl loader to use the "rpath" feature.
3315 AC_DEFUN([CF_LD_RPATH_OPT],
3316 [
3317 AC_REQUIRE([CF_CHECK_CACHE])
3318
3319 LD_RPATH_OPT=
3320 AC_MSG_CHECKING(for an rpath option)
3321 case $cf_cv_system_name in
3322 (irix*)
3323         if test "$GCC" = yes; then
3324                 LD_RPATH_OPT="-Wl,-rpath,"
3325         else
3326                 LD_RPATH_OPT="-rpath "
3327         fi
3328         ;;
3329 (linux*|gnu*|k*bsd*-gnu|freebsd*)
3330         LD_RPATH_OPT="-Wl,-rpath,"
3331         ;;
3332 (openbsd[[2-9]].*|mirbsd*)
3333         LD_RPATH_OPT="-Wl,-rpath,"
3334         ;;
3335 (dragonfly*)
3336         LD_RPATH_OPT="-rpath "
3337         ;;
3338 (netbsd*)
3339         LD_RPATH_OPT="-Wl,-rpath,"
3340         ;;
3341 (osf*|mls+*)
3342         LD_RPATH_OPT="-rpath "
3343         ;;
3344 (solaris2*)
3345         LD_RPATH_OPT="-R"
3346         ;;
3347 (*)
3348         ;;
3349 esac
3350 AC_MSG_RESULT($LD_RPATH_OPT)
3351
3352 case "x$LD_RPATH_OPT" in
3353 (x-R*)
3354         AC_MSG_CHECKING(if we need a space after rpath option)
3355         cf_save_LIBS="$LIBS"
3356         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3357         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3358         LIBS="$cf_save_LIBS"
3359         AC_MSG_RESULT($cf_rpath_space)
3360         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3361         ;;
3362 esac
3363 ])dnl
3364 dnl ---------------------------------------------------------------------------
3365 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
3366 dnl ---------------
3367 dnl Construct a search-list of directories for a nonstandard library-file
3368 dnl
3369 dnl Parameters
3370 dnl     $1 = the variable to return as result
3371 dnl     $2 = the package name
3372 AC_DEFUN([CF_LIBRARY_PATH],
3373 [
3374 $1=
3375 cf_library_path_list=""
3376 if test -n "${LDFLAGS}${LIBS}" ; then
3377         for cf_library_path in $LDFLAGS $LIBS
3378         do
3379                 case $cf_library_path in
3380                 (-L*)
3381                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3382                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3383                         cf_library_path_list="$cf_library_path_list [$]$1"
3384                         ;;
3385                 esac
3386         done
3387 fi
3388
3389 CF_SUBDIR_PATH($1,$2,lib)
3390
3391 $1="$cf_library_path_list [$]$1"
3392 ])dnl
3393 dnl ---------------------------------------------------------------------------
3394 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3395 dnl ------------------
3396 AC_DEFUN([CF_LIBTOOL_VERSION],[
3397 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3398 then
3399         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3400 else
3401         cf_cv_libtool_version=
3402 fi
3403 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3404 ])dnl
3405 dnl ---------------------------------------------------------------------------
3406 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
3407 dnl -------------
3408 dnl Compute the library-prefix for the given host system
3409 dnl $1 = variable to set
3410 define([CF_LIB_PREFIX],
3411 [
3412         case $cf_cv_system_name in
3413         (OS/2*|os2*)
3414                 if test "$DFT_LWR_MODEL" = libtool; then
3415                         LIB_PREFIX='lib'
3416                 else
3417                         LIB_PREFIX=''
3418                 fi
3419                 ;;
3420         (*)     LIB_PREFIX='lib'
3421                 ;;
3422         esac
3423 ifelse($1,,,[$1=$LIB_PREFIX])
3424         AC_SUBST(LIB_PREFIX)
3425 ])dnl
3426 dnl ---------------------------------------------------------------------------
3427 dnl CF_LIB_RULES version: 86 updated: 2015/11/07 20:01:34
3428 dnl ------------
3429 dnl Append definitions and rules for the given models to the subdirectory
3430 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3431 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3432 dnl the corresponding makefile to list the models that we'll generate.
3433 dnl
3434 dnl For shared libraries, make a list of symbolic links to construct when
3435 dnl generating each library.  The convention used for Linux is the simplest
3436 dnl one:
3437 dnl     lib<name>.so    ->
3438 dnl     lib<name>.so.<major>    ->
3439 dnl     lib<name>.so.<maj>.<minor>
3440 dnl
3441 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3442 AC_DEFUN([CF_LIB_RULES],
3443 [
3444 cf_prefix=$LIB_PREFIX
3445 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3446
3447 case $cf_cv_shlib_version in
3448 (cygdll|msysdll|mingw)
3449         TINFO_NAME=$TINFO_ARG_SUFFIX
3450         TINFO_SUFFIX=.dll
3451         ;;
3452 esac
3453
3454 if test -n "$TINFO_SUFFIX" ; then
3455         case $TINFO_SUFFIX in
3456         (tw*)
3457                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
3458                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
3459                 ;;
3460         (t*)
3461                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
3462                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
3463                 ;;
3464         (w*)
3465                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
3466                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
3467                 ;;
3468         esac
3469 fi
3470
3471 for cf_dir in $SRC_SUBDIRS
3472 do
3473         if test ! -d $srcdir/$cf_dir ; then
3474                 continue
3475         elif test -f $srcdir/$cf_dir/modules; then
3476
3477                 SHARED_LIB=
3478                 Libs_To_Make=
3479                 cf_awk_program=
3480                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
3481                 then
3482                         cf_awk_program="$cf_awk_program\
3483 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
3484 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
3485 "
3486                 fi
3487
3488                 if test "x$WILDCARD_SYMS" = xno
3489                 then
3490                         cf_awk_program="$cf_awk_program\
3491 /[[     ]]_\\*;/ { skip=1; next; }\
3492 "
3493                 fi
3494
3495                 if test "x$cf_awk_program" != "x"
3496                 then
3497                         cat >>$cf_dir/Makefile <<CF_EOF
3498
3499 # Generated by CF_LIB_RULES
3500 resulting.map: $UNALTERED_SYMS
3501         $AWK 'BEGIN { skip = 1; last=""; } \
3502 $cf_awk_program \
3503 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
3504  skip = 0; last = \[$]\[$]0; } \
3505 END { print last; }' < $UNALTERED_SYMS >\[$]@
3506
3507 distclean::
3508         rm -f resulting.map
3509 CF_EOF
3510                 fi
3511
3512                 for cf_item in $cf_LIST_MODELS
3513                 do
3514                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3515                         cf_libname=$cf_dir
3516                         test "$cf_dir" = c++ && cf_libname=ncurses++
3517                         if test $cf_item = shared ; then
3518                                 if test -n "${LIB_SUFFIX}"
3519                                 then
3520                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3521                                 else
3522                                         cf_shared_suffix="$cf_suffix"
3523                                 fi
3524                                 if test "$cf_cv_do_symlinks" = yes ; then
3525                                         cf_version_name=
3526
3527                                         case "$cf_cv_shlib_version" in
3528                                         (rel)
3529                                                 cf_version_name=REL_VERSION
3530                                                 ;;
3531                                         (abi)
3532                                                 cf_version_name=ABI_VERSION
3533                                                 ;;
3534                                         esac
3535
3536                                         if test -n "$cf_version_name"
3537                                         then
3538                                                 case "$cf_cv_system_name" in
3539                                                 (darwin*)
3540                                                         # "w", etc?
3541                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3542                                                         ;;
3543                                                 (*)
3544                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3545                                                         ;;
3546                                                 esac
3547                                         fi
3548                                         if test -n "${USE_LIB_SUFFIX}"
3549                                         then
3550                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3551                                         else
3552                                                 cf_shared_suffix="$cf_suffix"
3553                                         fi
3554                                 fi
3555                                 # cygwin needs import library, and has unique naming convention
3556                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3557                                 # use 'cyg' prefix for shared lib.
3558                                 case $cf_cv_shlib_version in
3559                                 (cygdll)
3560                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3561                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
3562                                         ;;
3563                                 (msysdll)
3564                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3565                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
3566                                         ;;
3567                                 (mingw)
3568                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3569                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
3570                                         ;;
3571                                 (*)
3572                                         cf_add_lib=
3573                                         ;;
3574                                 esac
3575                                 if test -n "$cf_add_lib"
3576                                 then
3577                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3578                                         continue
3579                                 fi
3580                         fi
3581                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3582                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3583                 done
3584
3585                 if test $cf_dir = ncurses ; then
3586                         cf_subsets="$LIB_SUBSETS"
3587                         cf_r_parts="$cf_subsets"
3588                         cf_liblist="$Libs_To_Make"
3589
3590                         while test -n "$cf_r_parts"
3591                         do
3592                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3593                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3594                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3595                                         cf_add_lib=
3596                                         case $cf_l_parts in
3597                                         (*termlib*)
3598                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3599                                                 ;;
3600                                         (*ticlib*)
3601                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3602                                                 ;;
3603                                         (*)
3604                                                 break
3605                                                 ;;
3606                                         esac
3607                                         if test -n "$cf_add_lib"; then
3608                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
3609                                         fi
3610                                 else
3611                                         break
3612                                 fi
3613                         done
3614                 else
3615                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3616                 fi
3617
3618                 if test $cf_dir = c++; then
3619                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3620                                 cf_list=
3621                                 for cf_item in $Libs_To_Make
3622                                 do
3623                                         case $cf_item in
3624                                         (*.a)
3625                                                 ;;
3626                                         (*)
3627                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3628                                                 ;;
3629                                         esac
3630                                         for cf_test in $cf_list
3631                                         do
3632                                                 if test "$cf_test" = "$cf_item"
3633                                                 then
3634                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3635                                                         cf_item=
3636                                                         break
3637                                                 fi
3638                                         done
3639                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3640                                 done
3641                                 Libs_To_Make="$cf_list"
3642                         fi
3643                 fi
3644
3645                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3646                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3647                         $cf_dir/Makefile >$cf_dir/Makefile.out
3648                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3649
3650                 $AWK -f $srcdir/mk-0th.awk \
3651                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3652                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3653
3654                 for cf_subset in $cf_subsets
3655                 do
3656                         cf_subdirs=
3657                         for cf_item in $cf_LIST_MODELS
3658                         do
3659
3660                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3661                         CF_UPPER(cf_ITEM,$cf_item)
3662
3663                         CXX_MODEL=$cf_ITEM
3664                         if test "$CXX_MODEL" = SHARED; then
3665                                 case $cf_cv_shlib_version in
3666                                 (cygdll|msysdll|mingw)
3667                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3668                                         with_shared_cxx=yes
3669                                         ;;
3670                                 (*)
3671                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3672                                         ;;
3673                                 esac
3674                         fi
3675
3676                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3677                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3678
3679                         # Test for case where we build libtinfo with a different name.
3680                         cf_libname=$cf_dir
3681                         if test $cf_dir = ncurses ; then
3682                                 case $cf_subset in
3683                                 (*base*)
3684                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
3685                                         ;;
3686                                 (*termlib*)
3687                                         cf_libname=$TINFO_LIB_SUFFIX
3688                                         ;;
3689                                 (ticlib*)
3690                                         cf_libname=$TICS_LIB_SUFFIX
3691                                         ;;
3692                                 esac
3693                         elif test $cf_dir = c++ ; then
3694                                 cf_libname=ncurses++$USE_LIB_SUFFIX
3695                         else
3696                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
3697                         fi
3698                         if test -n "${USE_ARG_SUFFIX}" ; then
3699                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
3700                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${USE_LIB_SUFFIX}%%"`
3701                         fi
3702
3703                         # These dependencies really are for development, not
3704                         # builds, but they are useful in porting, too.
3705                         cf_depend="../include/ncurses_cfg.h"
3706                         if test "$srcdir" = "."; then
3707                                 cf_reldir="."
3708                         else
3709                                 cf_reldir="\${srcdir}"
3710                         fi
3711
3712                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3713                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3714                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3715                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3716                         fi
3717
3718                         cf_dir_suffix=
3719                         old_cf_suffix="$cf_suffix"
3720                         if test "$cf_cv_shlib_version_infix" = yes ; then
3721                         if test -n "$USE_LIB_SUFFIX" ; then
3722                                 case $USE_LIB_SUFFIX in
3723                                 (tw*)
3724                                         cf_libname=`echo $cf_libname | sed 's/tw'$EXTRA_SUFFIX'$//'`
3725                                         cf_suffix=`echo $cf_suffix | sed 's/^tw'$EXTRA_SUFFIX'//'`
3726                                         cf_dir_suffix=tw$EXTRA_SUFFIX
3727                                         ;;
3728                                 (t*)
3729                                         cf_libname=`echo $cf_libname | sed 's/t'$EXTRA_SUFFIX'$//'`
3730                                         cf_suffix=`echo $cf_suffix | sed 's/^t'$EXTRA_SUFFIX'//'`
3731                                         cf_dir_suffix=t$EXTRA_SUFFIX
3732                                         ;;
3733                                 (w*)
3734                                         cf_libname=`echo $cf_libname | sed 's/w'$EXTRA_SUFFIX'$//'`
3735                                         cf_suffix=`echo $cf_suffix | sed 's/^w'$EXTRA_SUFFIX'//'`
3736                                         cf_dir_suffix=w$EXTRA_SUFFIX
3737                                         ;;
3738                                 (*)
3739                                         cf_libname=`echo $cf_libname | sed 's/'$EXTRA_SUFFIX'$//'`
3740                                         cf_suffix=`echo $cf_suffix | sed 's/^'$EXTRA_SUFFIX'//'`
3741                                         cf_dir_suffix=$EXTRA_SUFFIX
3742                                         ;;
3743                                 esac
3744                         fi
3745                         fi
3746
3747                         $AWK -f $srcdir/mk-1st.awk \
3748                                 name=${cf_libname}${cf_dir_suffix} \
3749                                 traces=$LIB_TRACING \
3750                                 MODEL=$cf_ITEM \
3751                                 CXX_MODEL=$CXX_MODEL \
3752                                 model=$cf_subdir \
3753                                 prefix=$cf_prefix \
3754                                 suffix=$cf_suffix \
3755                                 subset=$cf_subset \
3756                                 driver=$cf_cv_term_driver \
3757                                 SymLink="$LN_S" \
3758                                 TermlibRoot=$TINFO_NAME \
3759                                 TermlibSuffix=$TINFO_SUFFIX \
3760                                 ShlibVer=$cf_cv_shlib_version \
3761                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3762                                 ReLink=${cf_cv_do_relink:-no} \
3763                                 DoLinks=$cf_cv_do_symlinks \
3764                                 rmSoLocs=$cf_cv_rm_so_locs \
3765                                 ldconfig="$LDCONFIG" \
3766                                 overwrite=$WITH_OVERWRITE \
3767                                 depend="$cf_depend" \
3768                                 host="$host" \
3769                                 libtool_version="$LIBTOOL_VERSION" \
3770                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3771
3772                         cf_suffix="$old_cf_suffix"
3773
3774                         for cf_subdir2 in $cf_subdirs lib
3775                         do
3776                                 test $cf_subdir = $cf_subdir2 && break
3777                         done
3778                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3779                         $AWK -f $srcdir/mk-2nd.awk \
3780                                 name=$cf_dir \
3781                                 traces=$LIB_TRACING \
3782                                 MODEL=$cf_ITEM \
3783                                 model=$cf_subdir \
3784                                 subset=$cf_subset \
3785                                 srcdir=$srcdir \
3786                                 echo=$WITH_ECHO \
3787                                 crenames=$cf_cv_prog_CC_c_o \
3788                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3789                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3790                         cf_subdirs="$cf_subdirs $cf_subdir"
3791                         done
3792                 done
3793         fi
3794
3795         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
3796 done
3797
3798 for cf_dir in $SRC_SUBDIRS
3799 do
3800         if test ! -d $srcdir/$cf_dir ; then
3801                 continue
3802         fi
3803
3804         if test -f $cf_dir/Makefile ; then
3805                 case "$cf_dir" in
3806                 (Ada95)
3807                         echo 'libs \' >> Makefile
3808                         echo 'install.libs \' >> Makefile
3809                         echo 'uninstall.libs ::' >> Makefile
3810                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
3811                         ;;
3812                 esac
3813         fi
3814
3815         if test -f $srcdir/$cf_dir/modules; then
3816                 echo >> Makefile
3817                 if test -f $srcdir/$cf_dir/headers; then
3818 cat >> Makefile <<CF_EOF
3819 install.includes \\
3820 uninstall.includes \\
3821 CF_EOF
3822                 fi
3823 if test "$cf_dir" != "c++" ; then
3824 echo 'lint \' >> Makefile
3825 fi
3826 cat >> Makefile <<CF_EOF
3827 libs \\
3828 lintlib \\
3829 install.libs \\
3830 uninstall.libs \\
3831 install.$cf_dir \\
3832 uninstall.$cf_dir ::
3833         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3834 CF_EOF
3835         elif test -f $srcdir/$cf_dir/headers; then
3836 cat >> Makefile <<CF_EOF
3837
3838 libs \\
3839 install.libs \\
3840 uninstall.libs \\
3841 install.includes \\
3842 uninstall.includes ::
3843         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3844 CF_EOF
3845 fi
3846 done
3847
3848 if test "x$cf_with_db_install" = xyes; then
3849 cat >> Makefile <<CF_EOF
3850
3851 install.libs uninstall.libs \\
3852 install.data uninstall.data ::
3853 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3854 CF_EOF
3855 else
3856 cat >> Makefile <<CF_EOF
3857
3858 install.libs uninstall.libs ::
3859         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3860 CF_EOF
3861 fi
3862
3863 if test "x$cf_with_manpages" = xyes; then
3864 cat >> Makefile <<CF_EOF
3865
3866 install.man \\
3867 uninstall.man ::
3868         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
3869 CF_EOF
3870 fi
3871
3872 cat >> Makefile <<CF_EOF
3873
3874 distclean ::
3875         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3876         rm -f headers.sh headers.sed mk_shared_lib.sh
3877         rm -f edit_man.* man_alias.*
3878         rm -rf \${DIRS_TO_MAKE}
3879 CF_EOF
3880
3881 # Special case: tack's manpage lives in its own directory.
3882 if test "x$cf_with_manpages" = xyes; then
3883 if test -d tack ; then
3884 if test -f $srcdir/$tack.h; then
3885 cat >> Makefile <<CF_EOF
3886
3887 install.man \\
3888 uninstall.man ::
3889         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
3890 CF_EOF
3891 fi
3892 fi
3893 fi
3894
3895 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3896 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3897 dnl anything, and will make it more standardized.  It's awkward to decide this
3898 dnl at configuration because of quoting, so we'll simply make all headers
3899 dnl installed via a script that can do the right thing.
3900
3901 rm -f headers.sed headers.sh
3902
3903 dnl ( generating this script makes the makefiles a little tidier :-)
3904 echo creating headers.sh
3905 cat >headers.sh <<CF_EOF
3906 #! $SHELL
3907 # This shell script is generated by the 'configure' script.  It is invoked in a
3908 # subdirectory of the build tree.  It generates a sed-script in the parent
3909 # directory that is used to adjust includes for header files that reside in a
3910 # subdirectory of /usr/include, etc.
3911 PRG=""
3912 while test \[$]# != 3
3913 do
3914 PRG="\$PRG \[$]1"; shift
3915 done
3916 DST=\[$]1
3917 REF=\[$]2
3918 SRC=\[$]3
3919 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3920 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3921 echo installing \$SRC in \$DST
3922 CF_EOF
3923
3924 if test $WITH_CURSES_H = yes; then
3925         cat >>headers.sh <<CF_EOF
3926 case \$DST in
3927 (/*/include/*)
3928         END=\`basename \$DST\`
3929         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3930         do
3931                 NAME=\`basename \$i\`
3932                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3933         done
3934         ;;
3935 (*)
3936         echo "" >> \$TMPSED
3937         ;;
3938 esac
3939 CF_EOF
3940
3941 else
3942         cat >>headers.sh <<CF_EOF
3943 case \$DST in
3944 (/*/include/*)
3945         END=\`basename \$DST\`
3946         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3947         do
3948                 NAME=\`basename \$i\`
3949                 if test "\$NAME" = "curses.h"
3950                 then
3951                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3952                         NAME=ncurses.h
3953                 fi
3954                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3955         done
3956         ;;
3957 (*)
3958         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3959         ;;
3960 esac
3961 CF_EOF
3962 fi
3963 cat >>headers.sh <<CF_EOF
3964 rm -f \$TMPSRC
3965 sed -f \$TMPSED \$SRC > \$TMPSRC
3966 NAME=\`basename \$SRC\`
3967 CF_EOF
3968 if test $WITH_CURSES_H != yes; then
3969         cat >>headers.sh <<CF_EOF
3970 test "\$NAME" = "curses.h" && NAME=ncurses.h
3971 CF_EOF
3972 fi
3973 cat >>headers.sh <<CF_EOF
3974 # Just in case someone gzip'd manpages, remove the conflicting copy.
3975 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3976
3977 eval \$PRG \$TMPSRC \$DST/\$NAME
3978 rm -f \$TMPSRC \$TMPSED
3979 CF_EOF
3980
3981 chmod 0755 headers.sh
3982
3983 for cf_dir in $SRC_SUBDIRS
3984 do
3985         if test ! -d $srcdir/$cf_dir ; then
3986                 continue
3987         fi
3988
3989         if test -f $srcdir/$cf_dir/headers; then
3990                 $AWK -f $srcdir/mk-hdr.awk \
3991                         subset="$LIB_SUBSETS" \
3992                         compat="$WITH_CURSES_H" \
3993                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3994         fi
3995
3996         if test -f $srcdir/$cf_dir/modules; then
3997                 if test "$cf_dir" != "c++" ; then
3998                         cat >>$cf_dir/Makefile <<"CF_EOF"
3999 depend : ${AUTO_SRC}
4000         makedepend -- ${CPPFLAGS} -- ${C_SRC}
4001
4002 # DO NOT DELETE THIS LINE -- make depend depends on it.
4003 CF_EOF
4004                 fi
4005         fi
4006 done
4007 AC_SUBST(Libs_To_Make)
4008 ])dnl
4009 dnl ---------------------------------------------------------------------------
4010 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
4011 dnl -------------
4012 dnl Find the and soname for the given shared library.  Set the cache variable
4013 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
4014 dnl variable to "unknown".
4015 dnl
4016 dnl $1 = headers
4017 dnl $2 = code
4018 dnl $3 = library name
4019 AC_DEFUN([CF_LIB_SONAME],
4020 [
4021 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
4022
4023 cf_cv_$3_soname=unknown
4024 if test "$cross_compiling" != yes ; then
4025 cat >conftest.$ac_ext <<CF_EOF
4026 $1
4027 int main()
4028 {
4029 $2
4030         ${cf_cv_main_return:-return}(0);
4031 }
4032 CF_EOF
4033 cf_save_LIBS="$LIBS"
4034         CF_ADD_LIB($3)
4035         if AC_TRY_EVAL(ac_compile) ; then
4036                 if AC_TRY_EVAL(ac_link) ; then
4037                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
4038                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
4039                 fi
4040         fi
4041 rm -rf conftest*
4042 LIBS="$cf_save_LIBS"
4043 fi
4044 ])
4045 ])
4046 dnl ---------------------------------------------------------------------------
4047 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
4048 dnl -------------
4049 dnl Compute the library file-suffix from the given model name
4050 dnl $1 = model name
4051 dnl $2 = variable to set (the nominal library suffix)
4052 dnl $3 = dependency variable to set (actual filename)
4053 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4054 AC_DEFUN([CF_LIB_SUFFIX],
4055 [
4056         case X$1 in
4057         (Xlibtool)
4058                 $2='.la'
4059                 $3=[$]$2
4060                 ;;
4061         (Xdebug)
4062                 $2='_g.a'
4063                 $3=[$]$2
4064                 ;;
4065         (Xprofile)
4066                 $2='_p.a'
4067                 $3=[$]$2
4068                 ;;
4069         (Xshared)
4070                 case $cf_cv_system_name in
4071                 (aix[[5-7]]*)
4072                         $2='.so'
4073                         $3=[$]$2
4074                         ;;
4075                 (cygwin*|msys*|mingw*)
4076                         $2='.dll'
4077                         $3='.dll.a'
4078                         ;;
4079                 (darwin*)
4080                         $2='.dylib'
4081                         $3=[$]$2
4082                         ;;
4083                 (hpux*)
4084                         case $target in
4085                         (ia64*)
4086                                 $2='.so'
4087                                 $3=[$]$2
4088                                 ;;
4089                         (*)
4090                                 $2='.sl'
4091                                 $3=[$]$2
4092                                 ;;
4093                         esac
4094                         ;;
4095                 (*)
4096                         $2='.so'
4097                         $3=[$]$2
4098                         ;;
4099                 esac
4100                 ;;
4101         (*)
4102                 $2='.a'
4103                 $3=[$]$2
4104                 ;;
4105         esac
4106         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
4107         then
4108                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
4109                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
4110         fi
4111 ])dnl
4112 dnl ---------------------------------------------------------------------------
4113 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
4114 dnl -----------
4115 dnl Compute the string to append to -library from the given model name
4116 dnl $1 = model name
4117 dnl $2 = variable to set
4118 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4119 AC_DEFUN([CF_LIB_TYPE],
4120 [
4121         case $1 in
4122         (libtool) $2=''   ;;
4123         (normal)  $2=''   ;;
4124         (debug)   $2='_g' ;;
4125         (profile) $2='_p' ;;
4126         (shared)  $2=''   ;;
4127         esac
4128         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
4129 ])dnl
4130 dnl ---------------------------------------------------------------------------
4131 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
4132 dnl ----------------
4133 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
4134 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
4135 dnl have to provide wrappers for global tables to ensure they're linked
4136 dnl properly.
4137 AC_DEFUN([CF_LINK_DATAONLY],
4138 [
4139 AC_MSG_CHECKING([if data-only library module links])
4140 AC_CACHE_VAL(cf_cv_link_dataonly,[
4141         rm -f conftest.a
4142         cat >conftest.$ac_ext <<EOF
4143 #line __oline__ "configure"
4144 int     testdata[[3]] = { 123, 456, 789 };
4145 EOF
4146         if AC_TRY_EVAL(ac_compile) ; then
4147                 mv conftest.o data.o && \
4148                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
4149         fi
4150         rm -f conftest.$ac_ext data.o
4151         cat >conftest.$ac_ext <<EOF
4152 #line __oline__ "configure"
4153 int     testfunc()
4154 {
4155 #if defined(NeXT)
4156         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
4157 #else
4158         extern int testdata[[3]];
4159         return testdata[[0]] == 123
4160            &&  testdata[[1]] == 456
4161            &&  testdata[[2]] == 789;
4162 #endif
4163 }
4164 EOF
4165         if AC_TRY_EVAL(ac_compile); then
4166                 mv conftest.o func.o && \
4167                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
4168         fi
4169         rm -f conftest.$ac_ext func.o
4170         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
4171         cf_saveLIBS="$LIBS"
4172         LIBS="conftest.a $LIBS"
4173         AC_TRY_RUN([
4174         int main()
4175         {
4176                 extern int testfunc();
4177                 ${cf_cv_main_return:-return} (!testfunc());
4178         }
4179         ],
4180         [cf_cv_link_dataonly=yes],
4181         [cf_cv_link_dataonly=no],
4182         [cf_cv_link_dataonly=unknown])
4183         LIBS="$cf_saveLIBS"
4184         ])
4185 AC_MSG_RESULT($cf_cv_link_dataonly)
4186
4187 if test "$cf_cv_link_dataonly" = no ; then
4188         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
4189         BROKEN_LINKER=1
4190 fi
4191
4192 ])dnl
4193 dnl ---------------------------------------------------------------------------
4194 dnl CF_LINK_FUNCS version: 8 updated: 2012/10/06 17:56:13
4195 dnl -------------
4196 dnl Most Unix systems have both link and symlink, a few don't have symlink.
4197 dnl A few non-Unix systems implement symlink, but not link.
4198 dnl A few non-systems implement neither (or have nonfunctional versions).
4199 AC_DEFUN([CF_LINK_FUNCS],
4200 [
4201 AC_CHECK_FUNCS( \
4202         remove \
4203         unlink )
4204
4205 if test "$cross_compiling" = yes ; then
4206         AC_CHECK_FUNCS( \
4207                 link \
4208                 symlink )
4209 else
4210         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
4211                 cf_cv_link_funcs=
4212                 for cf_func in link symlink ; do
4213                         AC_TRY_RUN([
4214 #include <sys/types.h>
4215 #include <sys/stat.h>
4216 #ifdef HAVE_UNISTD_H
4217 #include <unistd.h>
4218 #endif
4219 int main()
4220 {
4221         int fail = 0;
4222         char *src = "config.log";
4223         char *dst = "conftest.chk";
4224         struct stat src_sb;
4225         struct stat dst_sb;
4226
4227         stat(src, &src_sb);
4228         fail = ($cf_func("config.log", "conftest.chk") < 0)
4229             || (stat(dst, &dst_sb) < 0)
4230             || (dst_sb.st_mtime != src_sb.st_mtime);
4231 #ifdef HAVE_UNLINK
4232         unlink(dst);
4233 #else
4234         remove(dst);
4235 #endif
4236         ${cf_cv_main_return:-return} (fail);
4237 }
4238                         ],[
4239                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
4240                         eval 'ac_cv_func_'$cf_func'=yes'],[
4241                         eval 'ac_cv_func_'$cf_func'=no'],[
4242                         eval 'ac_cv_func_'$cf_func'=error'])
4243                 done
4244                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
4245         ])
4246         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
4247         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
4248 fi
4249 ])dnl
4250 dnl ---------------------------------------------------------------------------
4251 dnl CF_MAKEFLAGS version: 17 updated: 2015/08/05 20:44:28
4252 dnl ------------
4253 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
4254 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
4255 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
4256 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
4257 AC_DEFUN([CF_MAKEFLAGS],
4258 [
4259 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
4260         cf_cv_makeflags=''
4261         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
4262         do
4263                 cat >cf_makeflags.tmp <<CF_EOF
4264 SHELL = $SHELL
4265 all :
4266         @ echo '.$cf_option'
4267 CF_EOF
4268                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
4269                 case "$cf_result" in
4270                 (.*k|.*kw)
4271                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
4272                         case "$cf_result" in
4273                         (.*CC=*)        cf_cv_makeflags=
4274                                 ;;
4275                         (*)     cf_cv_makeflags=$cf_option
4276                                 ;;
4277                         esac
4278                         break
4279                         ;;
4280                 (.-)    ;;
4281                 (*)     echo "given option \"$cf_option\", no match \"$cf_result\""
4282                         ;;
4283                 esac
4284         done
4285         rm -f cf_makeflags.tmp
4286 ])
4287
4288 AC_SUBST(cf_cv_makeflags)
4289 ])dnl
4290 dnl ---------------------------------------------------------------------------
4291 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
4292 dnl ------------
4293 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
4294 dnl a monocase filesystem.
4295 AC_DEFUN([CF_MAKE_TAGS],[
4296 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
4297
4298 AC_CHECK_PROGS(CTAGS, exctags ctags)
4299 AC_CHECK_PROGS(ETAGS, exetags etags)
4300
4301 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
4302
4303 if test "$cf_cv_mixedcase" = yes ; then
4304         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
4305 else
4306         MAKE_UPPER_TAGS=no
4307 fi
4308
4309 if test "$MAKE_UPPER_TAGS" = yes ; then
4310         MAKE_UPPER_TAGS=
4311 else
4312         MAKE_UPPER_TAGS="#"
4313 fi
4314
4315 if test "$MAKE_LOWER_TAGS" = yes ; then
4316         MAKE_LOWER_TAGS=
4317 else
4318         MAKE_LOWER_TAGS="#"
4319 fi
4320
4321 AC_SUBST(CTAGS)
4322 AC_SUBST(ETAGS)
4323
4324 AC_SUBST(MAKE_UPPER_TAGS)
4325 AC_SUBST(MAKE_LOWER_TAGS)
4326 ])dnl
4327 dnl ---------------------------------------------------------------------------
4328 dnl CF_MANPAGE_FORMAT version: 11 updated: 2015/04/18 08:56:57
4329 dnl -----------------
4330 dnl Option to allow user to override automatic configuration of manpage format.
4331 dnl There are several special cases:
4332 dnl
4333 dnl     gzip - man checks for, can display gzip'd files
4334 dnl     compress - man checks for, can display compressed files
4335 dnl     BSDI - files in the cat-directories are suffixed ".0"
4336 dnl     formatted - installer should format (put files in cat-directory)
4337 dnl     catonly - installer should only format, e.g., for a turnkey system.
4338 dnl
4339 dnl There are other configurations which this macro does not test, e.g., HPUX's
4340 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
4341 dnl convention would not match our use).
4342 AC_DEFUN([CF_MANPAGE_FORMAT],
4343 [
4344 AC_REQUIRE([CF_PATHSEP])
4345 AC_MSG_CHECKING(format of man-pages)
4346
4347 AC_ARG_WITH(manpage-format,
4348         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
4349                           optionally formatted/catonly, e.g., gzip,formatted],
4350         [MANPAGE_FORMAT=$withval],
4351         [MANPAGE_FORMAT=unknown])
4352
4353 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
4354 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
4355
4356 cf_unknown=
4357
4358 case $MANPAGE_FORMAT in
4359 (unknown)
4360         if test -z "$MANPATH" ; then
4361                 MANPATH="/usr/man:/usr/share/man"
4362         fi
4363
4364         # look for the 'date' man-page (it's most likely to be installed!)
4365         MANPAGE_FORMAT=
4366         cf_preform=no
4367         cf_catonly=yes
4368         cf_example=date
4369
4370         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
4371         for cf_dir in $MANPATH; do
4372                 test -z "$cf_dir" && cf_dir=/usr/man
4373                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
4374                 do
4375                         cf_test=`echo $cf_name | sed -e 's/*//'`
4376                         if test "x$cf_test" = "x$cf_name" ; then
4377
4378                                 case "$cf_name" in
4379                                 (*.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
4380                                 (*.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
4381                                 (*.0)  MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
4382                                 (*)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
4383                                 esac
4384
4385                                 case "$cf_name" in
4386                                 ($cf_dir/man*)
4387                                         cf_catonly=no
4388                                         ;;
4389                                 ($cf_dir/cat*)
4390                                         cf_preform=yes
4391                                         ;;
4392                                 esac
4393                                 break
4394                         fi
4395
4396                         # if we found a match in either man* or cat*, stop looking
4397                         if test -n "$MANPAGE_FORMAT" ; then
4398                                 cf_found=no
4399                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
4400                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
4401                                 case "$cf_name" in
4402                                 ($cf_dir/cat*)
4403                                         cf_found=yes
4404                                         ;;
4405                                 esac
4406                                 test $cf_found=yes && break
4407                         fi
4408                 done
4409                 # only check the first directory in $MANPATH where we find manpages
4410                 if test -n "$MANPAGE_FORMAT" ; then
4411                         break
4412                 fi
4413         done
4414         # if we did not find the example, just assume it is normal
4415         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
4416         IFS="$ac_save_ifs"
4417         ;;
4418 (*)
4419         for cf_option in $MANPAGE_FORMAT; do
4420         case $cf_option in
4421         (gzip|compress|BSDI|normal|formatted|catonly)
4422                 ;;
4423         (*)
4424                 cf_unknown="$cf_unknown $cf_option"
4425                 ;;
4426         esac
4427         done
4428         ;;
4429 esac
4430
4431 AC_MSG_RESULT($MANPAGE_FORMAT)
4432 if test -n "$cf_unknown" ; then
4433         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
4434 fi
4435 ])dnl
4436 dnl ---------------------------------------------------------------------------
4437 dnl CF_MANPAGE_RENAMES version: 10 updated: 2015/08/05 20:44:28
4438 dnl ------------------
4439 dnl The Debian people have their own naming convention for manpages.  This
4440 dnl option lets us override the name of the file containing renaming, or
4441 dnl disable it altogether.
4442 AC_DEFUN([CF_MANPAGE_RENAMES],
4443 [
4444 AC_MSG_CHECKING(for manpage renaming)
4445
4446 AC_ARG_WITH(manpage-renames,
4447         [  --with-manpage-renames  specify manpage-renaming],
4448         [MANPAGE_RENAMES=$withval],
4449         [MANPAGE_RENAMES=yes])
4450
4451 case ".$MANPAGE_RENAMES" in
4452 (.no)
4453         ;;
4454 (.|.yes)
4455         # Debian 'man' program?
4456         if test -f /etc/debian_version ; then
4457                 MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
4458         else
4459                 MANPAGE_RENAMES=no
4460         fi
4461         ;;
4462 esac
4463
4464 if test "$MANPAGE_RENAMES" != no ; then
4465         if test -f $srcdir/man/$MANPAGE_RENAMES ; then
4466                 MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
4467         elif test ! -f $MANPAGE_RENAMES ; then
4468                 AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
4469         fi
4470
4471         test ! -d man && mkdir man
4472
4473         # Construct a sed-script to perform renaming within man-pages
4474         if test -n "$MANPAGE_RENAMES" ; then
4475                 test ! -d man && mkdir man
4476                 $SHELL $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
4477         fi
4478 fi
4479
4480 AC_MSG_RESULT($MANPAGE_RENAMES)
4481 AC_SUBST(MANPAGE_RENAMES)
4482 ])dnl
4483 dnl ---------------------------------------------------------------------------
4484 dnl CF_MANPAGE_SYMLINKS version: 6 updated: 2015/04/17 21:13:04
4485 dnl -------------------
4486 dnl Some people expect each tool to make all aliases for manpages in the
4487 dnl man-directory.  This accommodates the older, less-capable implementations
4488 dnl of 'man', and is optional.
4489 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4490 [
4491 AC_MSG_CHECKING(if manpage aliases will be installed)
4492
4493 AC_ARG_WITH(manpage-aliases,
4494         [  --with-manpage-aliases  specify manpage-aliases using .so],
4495         [MANPAGE_ALIASES=$withval],
4496         [MANPAGE_ALIASES=yes])
4497
4498 AC_MSG_RESULT($MANPAGE_ALIASES)
4499
4500 case "x$LN_S" in
4501 (xln*)
4502         cf_use_symlinks=yes
4503         ;;
4504 (*)
4505         cf_use_symlinks=no
4506         ;;
4507 esac
4508
4509 MANPAGE_SYMLINKS=no
4510 if test "$MANPAGE_ALIASES" = yes ; then
4511 AC_MSG_CHECKING(if manpage symlinks should be used)
4512
4513 AC_ARG_WITH(manpage-symlinks,
4514         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
4515         [MANPAGE_SYMLINKS=$withval],
4516         [MANPAGE_SYMLINKS=$cf_use_symlinks])
4517
4518 if test "$$cf_use_symlinks" = no; then
4519 if test "$MANPAGE_SYMLINKS" = yes ; then
4520         AC_MSG_WARN(cannot make symlinks, will use .so files)
4521         MANPAGE_SYMLINKS=no
4522 fi
4523 fi
4524
4525 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4526 fi
4527
4528 ])dnl
4529 dnl ---------------------------------------------------------------------------
4530 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4531 dnl --------------
4532 dnl This option causes manpages to be run through tbl(1) to generate tables
4533 dnl correctly.
4534 AC_DEFUN([CF_MANPAGE_TBL],
4535 [
4536 AC_MSG_CHECKING(for manpage tbl)
4537
4538 AC_ARG_WITH(manpage-tbl,
4539         [  --with-manpage-tbl      specify manpage processing with tbl],
4540         [MANPAGE_TBL=$withval],
4541         [MANPAGE_TBL=no])
4542
4543 AC_MSG_RESULT($MANPAGE_TBL)
4544 ])dnl
4545 dnl ---------------------------------------------------------------------------
4546 dnl CF_MAN_PAGES version: 46 updated: 2015/08/05 20:44:28
4547 dnl ------------
4548 dnl Try to determine if the man-pages on the system are compressed, and if
4549 dnl so, what format is used.  Use this information to construct a script that
4550 dnl will install man-pages.
4551 AC_DEFUN([CF_MAN_PAGES],
4552 [
4553 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4554 CF_MANPAGE_FORMAT
4555 CF_MANPAGE_RENAMES
4556 CF_MANPAGE_SYMLINKS
4557 CF_MANPAGE_TBL
4558
4559 if test "$prefix" = "NONE" ; then
4560         cf_prefix="$ac_default_prefix"
4561 else
4562         cf_prefix="$prefix"
4563 fi
4564
4565 case "$MANPAGE_FORMAT" in
4566 (*catonly*)
4567         cf_format=yes
4568         cf_inboth=no
4569         ;;
4570 (*formatted*)
4571         cf_format=yes
4572         cf_inboth=yes
4573         ;;
4574 (*)
4575         cf_format=no
4576         cf_inboth=no
4577         ;;
4578 esac
4579
4580 test ! -d man && mkdir man
4581
4582 cf_so_strip=
4583 cf_compress=
4584 case "$MANPAGE_FORMAT" in
4585 (*compress*)
4586         cf_so_strip="Z"
4587         cf_compress=compress
4588         ;;
4589 (*gzip*)
4590         cf_so_strip="gz"
4591         cf_compress=gzip
4592         ;;
4593 esac
4594
4595 cf_edit_man=./edit_man.sh
4596 cf_man_alias=`pwd`/man_alias.sed
4597
4598 cat >$cf_edit_man <<CF_EOF
4599 #! $SHELL
4600 # this script is generated by the configure-script CF_MAN_PAGES macro.
4601
4602 prefix="$cf_prefix"
4603 datarootdir="$datarootdir"
4604 datadir="$datadir"
4605
4606 NCURSES_MAJOR="$NCURSES_MAJOR"
4607 NCURSES_MINOR="$NCURSES_MINOR"
4608 NCURSES_PATCH="$NCURSES_PATCH"
4609
4610 NCURSES_OSPEED="$NCURSES_OSPEED"
4611 TERMINFO="$TERMINFO"
4612
4613 INSTALL="$INSTALL"
4614 INSTALL_DATA="$INSTALL_DATA"
4615
4616 transform="$program_transform_name"
4617
4618 TMP=\${TMPDIR:=/tmp}/man\$\$
4619 trap "rm -f \$TMP" 0 1 2 5 15
4620
4621 form=\[$]1
4622 shift || exit 1
4623
4624 verb=\[$]1
4625 shift || exit 1
4626
4627 mandir=\[$]1
4628 shift || exit 1
4629
4630 srcdir=\[$]1
4631 top_srcdir=\[$]srcdir/..
4632 shift || exit 1
4633
4634 if test "\$form" = normal ; then
4635         if test "$cf_format" = yes ; then
4636         if test "$cf_inboth" = no ; then
4637                 $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
4638                 exit $?
4639         fi
4640         fi
4641         cf_subdir=\$mandir/man
4642         cf_tables=$MANPAGE_TBL
4643 else
4644         cf_subdir=\$mandir/cat
4645         cf_tables=yes
4646 fi
4647
4648 # process the list of source-files
4649 for i in \[$]* ; do
4650 case \$i in
4651 (*.orig|*.rej) ;;
4652 (*.[[0-9]]*)
4653         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4654         if test \$verb = installing ; then
4655         if test ! -d \$cf_subdir\${section} ; then
4656                 mkdir -p \$cf_subdir\$section
4657         fi
4658         fi
4659
4660         # replace variables in man page
4661         if test ! -f $cf_man_alias ; then
4662 cat >>$cf_man_alias <<-CF_EOF2
4663                 s,@DATADIR@,\$datadir,g
4664                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
4665                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
4666                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
4667                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
4668                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
4669                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
4670 CF_EOF
4671         ifelse($1,,,[
4672         for cf_name in $1
4673         do
4674                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4675                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4676 cat >>$cf_edit_man <<-CF_EOF
4677                 s,@$cf_NAME@,$cf_name,g
4678 CF_EOF
4679         done
4680         ])
4681 cat >>$cf_edit_man <<CF_EOF
4682 CF_EOF2
4683                 echo "...made $cf_man_alias"
4684         fi
4685
4686         aliases=
4687         cf_source=\`basename \$i\`
4688         inalias=\$cf_source
4689         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4690         if test ! -f \$inalias ; then
4691                 echo .. skipped \$cf_source
4692                 continue
4693         fi
4694 CF_EOF
4695
4696 if test "$MANPAGE_ALIASES" != no ; then
4697 cat >>$cf_edit_man <<CF_EOF
4698         nCurses=ignore.3x
4699         test $with_curses_h = yes && nCurses=ncurses.3x
4700         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4701 CF_EOF
4702 fi
4703
4704 if test "$MANPAGE_RENAMES" = no ; then
4705 cat >>$cf_edit_man <<CF_EOF
4706         # perform program transformations for section 1 man pages
4707         if test \$section = 1 ; then
4708                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4709         else
4710                 cf_target=\$cf_subdir\${section}/\$cf_source
4711         fi
4712 CF_EOF
4713 else
4714 cat >>$cf_edit_man <<CF_EOF
4715         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4716         if test -z "\$cf_target" ; then
4717                 echo '? missing rename for '\$cf_source
4718                 cf_target="\$cf_source"
4719         fi
4720         cf_target="\$cf_subdir\${section}/\${cf_target}"
4721
4722 CF_EOF
4723 fi
4724
4725 cat >>$cf_edit_man <<CF_EOF
4726         sed     -f $cf_man_alias \\
4727 CF_EOF
4728
4729 if test -f $MANPAGE_RENAMES ; then
4730 cat >>$cf_edit_man <<CF_EOF
4731                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4732 CF_EOF
4733 else
4734 cat >>$cf_edit_man <<CF_EOF
4735                 < \$i >\$TMP
4736 CF_EOF
4737 fi
4738
4739 cat >>$cf_edit_man <<CF_EOF
4740 if test \$cf_tables = yes ; then
4741         tbl \$TMP >\$TMP.out
4742         mv \$TMP.out \$TMP
4743 fi
4744 CF_EOF
4745
4746 if test $with_overwrite != yes ; then
4747 cat >>$cf_edit_man <<CF_EOF
4748         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
4749         mv \$TMP.out \$TMP
4750 CF_EOF
4751 fi
4752
4753 if test $with_curses_h != yes ; then
4754 cat >>$cf_edit_man <<CF_EOF
4755         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4756         mv \$TMP.out \$TMP
4757 CF_EOF
4758 fi
4759
4760 cat >>$cf_edit_man <<CF_EOF
4761         if test \$form = format ; then
4762                 nroff -man \$TMP >\$TMP.out
4763                 mv \$TMP.out \$TMP
4764         fi
4765 CF_EOF
4766
4767 if test -n "$cf_compress" ; then
4768 cat >>$cf_edit_man <<CF_EOF
4769         if test \$verb = installing ; then
4770         if ( $cf_compress -f \$TMP )
4771         then
4772                 mv \$TMP.$cf_so_strip \$TMP
4773         fi
4774         fi
4775         cf_target="\$cf_target.$cf_so_strip"
4776 CF_EOF
4777 fi
4778
4779 case "$MANPAGE_FORMAT" in
4780 (*BSDI*)
4781 cat >>$cf_edit_man <<CF_EOF
4782         if test \$form = format ; then
4783                 # BSDI installs only .0 suffixes in the cat directories
4784                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
4785         fi
4786 CF_EOF
4787   ;;
4788 esac
4789
4790 cat >>$cf_edit_man <<CF_EOF
4791         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
4792         if test \$verb = installing ; then
4793                 echo \$verb \$cf_target
4794                 \$INSTALL_DATA \$TMP \$cf_target
4795                 test -d \$cf_subdir\${section} &&
4796                 test -n "\$aliases" && (
4797                         cd \$cf_subdir\${section} && (
4798                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
4799                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
4800                                 cf_target=\`basename \$cf_target\`
4801                                 for cf_alias in \$aliases
4802                                 do
4803                                         if test \$section = 1 ; then
4804                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4805                                         fi
4806
4807                                         if test "$MANPAGE_SYMLINKS" = yes ; then
4808                                                 if test -f \$cf_alias\${suffix} ; then
4809                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
4810                                                         then
4811                                                                 continue
4812                                                         fi
4813                                                 fi
4814                                                 echo .. \$verb alias \$cf_alias\${suffix}
4815 CF_EOF
4816 case "x$LN_S" in
4817 (*-f)
4818 cat >>$cf_edit_man <<CF_EOF
4819                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4820 CF_EOF
4821         ;;
4822 (*)
4823 cat >>$cf_edit_man <<CF_EOF
4824                                                 rm -f \$cf_alias\${suffix}
4825                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4826 CF_EOF
4827         ;;
4828 esac
4829 cat >>$cf_edit_man <<CF_EOF
4830                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
4831                                                 echo ".so \$cf_source" >\$TMP
4832 CF_EOF
4833 if test -n "$cf_compress" ; then
4834 cat >>$cf_edit_man <<CF_EOF
4835                                                 if test -n "$cf_so_strip" ; then
4836                                                         $cf_compress -f \$TMP
4837                                                         mv \$TMP.$cf_so_strip \$TMP
4838                                                 fi
4839 CF_EOF
4840 fi
4841 cat >>$cf_edit_man <<CF_EOF
4842                                                 echo .. \$verb alias \$cf_alias\${suffix}
4843                                                 rm -f \$cf_alias\${suffix}
4844                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
4845                                         fi
4846                                 done
4847                         )
4848                 )
4849         elif test \$verb = removing ; then
4850                 test -f \$cf_target && (
4851                         echo \$verb \$cf_target
4852                         rm -f \$cf_target
4853                 )
4854                 test -d \$cf_subdir\${section} &&
4855                 test -n "\$aliases" && (
4856                         cd \$cf_subdir\${section} && (
4857                                 for cf_alias in \$aliases
4858                                 do
4859                                         if test \$section = 1 ; then
4860                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4861                                         fi
4862
4863                                         echo .. \$verb alias \$cf_alias\${suffix}
4864                                         rm -f \$cf_alias\${suffix}
4865                                 done
4866                         )
4867                 )
4868         else
4869 #               echo ".hy 0"
4870                 cat \$TMP
4871         fi
4872         ;;
4873 esac
4874 done
4875
4876 if test $cf_inboth = yes ; then
4877 if test \$form != format ; then
4878         $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
4879 fi
4880 fi
4881
4882 exit 0
4883 CF_EOF
4884 chmod 755 $cf_edit_man
4885
4886 ])dnl
4887 dnl ---------------------------------------------------------------------------
4888 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
4889 dnl -----------
4890 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
4891 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
4892 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
4893 AC_DEFUN([CF_MATH_LIB],
4894 [
4895 AC_CACHE_CHECK(if -lm needed for math functions,
4896         cf_cv_need_libm,[
4897         AC_TRY_LINK([
4898         #include <stdio.h>
4899         #include <math.h>
4900         ],
4901         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
4902         [cf_cv_need_libm=no],
4903         [cf_cv_need_libm=yes])])
4904 if test "$cf_cv_need_libm" = yes
4905 then
4906 ifelse($1,,[
4907         CF_ADD_LIB(m)
4908 ],[$1=-lm])
4909 fi
4910 ])
4911 dnl ---------------------------------------------------------------------------
4912 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
4913 dnl ----------------------
4914 dnl Check if the file-system supports mixed-case filenames.  If we're able to
4915 dnl create a lowercase name and see it as uppercase, it doesn't support that.
4916 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
4917 [
4918 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
4919 if test "$cross_compiling" = yes ; then
4920         case $target_alias in
4921         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
4922                 cf_cv_mixedcase=no
4923                 ;;
4924         (*)
4925                 cf_cv_mixedcase=yes
4926                 ;;
4927         esac
4928 else
4929         rm -f conftest CONFTEST
4930         echo test >conftest
4931         if test -f CONFTEST ; then
4932                 cf_cv_mixedcase=no
4933         else
4934                 cf_cv_mixedcase=yes
4935         fi
4936         rm -f conftest CONFTEST
4937 fi
4938 ])
4939 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
4940 ])dnl
4941 dnl ---------------------------------------------------------------------------
4942 dnl CF_MKSTEMP version: 9 updated: 2012/10/03 04:34:49
4943 dnl ----------
4944 dnl Check for a working mkstemp.  This creates two files, checks that they are
4945 dnl successfully created and distinct (AmigaOS apparently fails on the last).
4946 AC_DEFUN([CF_MKSTEMP],[
4947 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
4948 rm -rf conftest*
4949 AC_TRY_RUN([
4950 #include <sys/types.h>
4951 #include <stdlib.h>
4952 #include <stdio.h>
4953 #include <string.h>
4954 #include <sys/stat.h>
4955 int main()
4956 {
4957         char *tmpl = "conftestXXXXXX";
4958         char name[2][80];
4959         int n;
4960         int result = 0;
4961         int fd;
4962         struct stat sb;
4963
4964         umask(077);
4965         for (n = 0; n < 2; ++n) {
4966                 strcpy(name[n], tmpl);
4967                 if ((fd = mkstemp(name[n])) >= 0) {
4968                         if (!strcmp(name[n], tmpl)
4969                          || stat(name[n], &sb) != 0
4970                          || (sb.st_mode & S_IFMT) != S_IFREG
4971                          || (sb.st_mode & 077) != 0) {
4972                                 result = 1;
4973                         }
4974                         close(fd);
4975                 }
4976         }
4977         if (result == 0
4978          && !strcmp(name[0], name[1]))
4979                 result = 1;
4980         ${cf_cv_main_return:-return}(result);
4981 }
4982 ],[cf_cv_func_mkstemp=yes
4983 ],[cf_cv_func_mkstemp=no
4984 ],[cf_cv_func_mkstemp=maybe])
4985 ])
4986 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
4987         AC_CHECK_FUNC(mkstemp)
4988 fi
4989 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
4990         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
4991 fi
4992 ])dnl
4993 dnl ---------------------------------------------------------------------------
4994 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
4995 dnl ----------
4996 dnl Write a debug message to config.log, along with the line number in the
4997 dnl configure script.
4998 AC_DEFUN([CF_MSG_LOG],[
4999 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
5000 ])dnl
5001 dnl ---------------------------------------------------------------------------
5002 dnl CF_NCURSES_ABI_6 version: 3 updated: 2015/06/06 16:10:11
5003 dnl ----------------
5004 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
5005 dnl warn about this.
5006 AC_DEFUN([CF_NCURSES_ABI_6],[
5007 if test "${with_abi_version+set}" != set; then
5008         case $cf_cv_rel_version in
5009         (5.*)
5010                 cf_cv_rel_version=6.0
5011                 cf_cv_abi_version=6
5012                 AC_MSG_WARN(overriding ABI version to $cf_cv_abi_version)
5013                 ;;
5014         esac
5015 fi
5016 ])dnl
5017 dnl ---------------------------------------------------------------------------
5018 dnl CF_NCURSES_WITH_ABI_VERSION version: 2 updated: 2015/12/19 17:51:52
5019 dnl ---------------------------
5020 dnl Allow ncurses's ABI to be overridden.  Generally this happens when a
5021 dnl packager has incremented the ABI past that used in the original package,
5022 dnl and wishes to keep doing this.
5023 dnl
5024 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
5025 dnl symbol.
5026 AC_DEFUN([CF_NCURSES_WITH_ABI_VERSION],[
5027 CF_WITH_ABI_VERSION($1)
5028 if test "x$cf_cv_abi_version" != "x$with_abi_version"
5029 then
5030         case $cf_cv_rel_version in
5031         (5.*)
5032                 cf_cv_rel_version=$with_abi_version.0
5033                 ;;
5034         esac
5035 fi
5036 ])dnl
5037 dnl ---------------------------------------------------------------------------
5038 dnl CF_NO_LEAKS_OPTION version: 6 updated: 2015/04/12 15:39:00
5039 dnl ------------------
5040 dnl see CF_WITH_NO_LEAKS
5041 AC_DEFUN([CF_NO_LEAKS_OPTION],[
5042 AC_MSG_CHECKING(if you want to use $1 for testing)
5043 AC_ARG_WITH($1,
5044         [$2],
5045         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
5046          $4
5047 ])
5048         : ${with_cflags:=-g}
5049         : ${with_no_leaks:=yes}
5050          with_$1=yes],
5051         [with_$1=])
5052 AC_MSG_RESULT(${with_$1:-no})
5053
5054 case .$with_cflags in
5055 (.*-g*)
5056         case .$CFLAGS in
5057         (.*-g*)
5058                 ;;
5059         (*)
5060                 CF_ADD_CFLAGS([-g])
5061                 ;;
5062         esac
5063         ;;
5064 esac
5065 ])dnl
5066 dnl ---------------------------------------------------------------------------
5067 dnl CF_NUMBER_SYNTAX version: 2 updated: 2015/04/17 21:13:04
5068 dnl ----------------
5069 dnl Check if the given variable is a number.  If not, report an error.
5070 dnl $1 is the variable
5071 dnl $2 is the message
5072 AC_DEFUN([CF_NUMBER_SYNTAX],[
5073 if test -n "$1" ; then
5074   case $1 in
5075   ([[0-9]]*)
5076         ;;
5077   (*)
5078         AC_MSG_ERROR($2 is not a number: $1)
5079         ;;
5080   esac
5081 else
5082   AC_MSG_ERROR($2 value is empty)
5083 fi
5084 ])dnl
5085 dnl ---------------------------------------------------------------------------
5086 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
5087 dnl -------------
5088 dnl Compute the object-directory name from the given model name
5089 AC_DEFUN([CF_OBJ_SUBDIR],
5090 [
5091         case $1 in
5092         (libtool) $2='obj_lo'  ;;
5093         (normal)  $2='objects' ;;
5094         (debug)   $2='obj_g' ;;
5095         (profile) $2='obj_p' ;;
5096         (shared)
5097                 case $cf_cv_system_name in
5098                 (cygwin|msys)
5099                         $2='objects' ;;
5100                 (*)
5101                         $2='obj_s' ;;
5102                 esac
5103         esac
5104 ])dnl
5105 dnl ---------------------------------------------------------------------------
5106 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
5107 dnl ----------
5108 dnl Provide a value for the $PATH and similar separator (or amend the value
5109 dnl as provided in autoconf 2.5x).
5110 AC_DEFUN([CF_PATHSEP],
5111 [
5112         AC_MSG_CHECKING(for PATH separator)
5113         case $cf_cv_system_name in
5114         (os2*)  PATH_SEPARATOR=';'  ;;
5115         (*)     ${PATH_SEPARATOR:=':'}  ;;
5116         esac
5117 ifelse([$1],,,[$1=$PATH_SEPARATOR])
5118         AC_SUBST(PATH_SEPARATOR)
5119         AC_MSG_RESULT($PATH_SEPARATOR)
5120 ])dnl
5121 dnl ---------------------------------------------------------------------------
5122 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
5123 dnl --------------
5124 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
5125 dnl begins with one of the prefix/exec_prefix variables, and then again if the
5126 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
5127 dnl delayed evaluation of those symbols.
5128 AC_DEFUN([CF_PATH_SYNTAX],[
5129 if test "x$prefix" != xNONE; then
5130         cf_path_syntax="$prefix"
5131 else
5132         cf_path_syntax="$ac_default_prefix"
5133 fi
5134
5135 case ".[$]$1" in
5136 (.\[$]\(*\)*|.\'*\'*)
5137         ;;
5138 (..|./*|.\\*)
5139         ;;
5140 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
5141         ;;
5142 (.\[$]{*prefix}*|.\[$]{*dir}*)
5143         eval $1="[$]$1"
5144         case ".[$]$1" in
5145         (.NONE/*)
5146                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
5147                 ;;
5148         esac
5149         ;;
5150 (.no|.NONE/*)
5151         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
5152         ;;
5153 (*)
5154         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
5155         ;;
5156 esac
5157 ])dnl
5158 dnl ---------------------------------------------------------------------------
5159 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
5160 dnl -------------
5161 dnl Check for the package-config program, unless disabled by command-line.
5162 AC_DEFUN([CF_PKG_CONFIG],
5163 [
5164 AC_MSG_CHECKING(if you want to use pkg-config)
5165 AC_ARG_WITH(pkg-config,
5166         [  --with-pkg-config{=path} enable/disable use of pkg-config],
5167         [cf_pkg_config=$withval],
5168         [cf_pkg_config=yes])
5169 AC_MSG_RESULT($cf_pkg_config)
5170
5171 case $cf_pkg_config in
5172 (no)
5173         PKG_CONFIG=none
5174         ;;
5175 (yes)
5176         CF_ACVERSION_CHECK(2.52,
5177                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
5178                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
5179         ;;
5180 (*)
5181         PKG_CONFIG=$withval
5182         ;;
5183 esac
5184
5185 test -z "$PKG_CONFIG" && PKG_CONFIG=none
5186 if test "$PKG_CONFIG" != none ; then
5187         CF_PATH_SYNTAX(PKG_CONFIG)
5188 elif test "x$cf_pkg_config" != xno ; then
5189         AC_MSG_WARN(pkg-config is not installed)
5190 fi
5191
5192 AC_SUBST(PKG_CONFIG)
5193 ])dnl
5194 dnl ---------------------------------------------------------------------------
5195 dnl CF_POSIX_C_SOURCE version: 9 updated: 2015/04/12 15:39:00
5196 dnl -----------------
5197 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
5198 dnl
5199 dnl     POSIX.1-1990                            _POSIX_SOURCE
5200 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
5201 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
5202 dnl             Bindings Option
5203 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
5204 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
5205 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
5206 dnl
5207 dnl Parameters:
5208 dnl     $1 is the nominal value for _POSIX_C_SOURCE
5209 AC_DEFUN([CF_POSIX_C_SOURCE],
5210 [
5211 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
5212
5213 cf_save_CFLAGS="$CFLAGS"
5214 cf_save_CPPFLAGS="$CPPFLAGS"
5215
5216 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
5217 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
5218
5219 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
5220         CF_MSG_LOG(if the symbol is already defined go no further)
5221         AC_TRY_COMPILE([#include <sys/types.h>],[
5222 #ifndef _POSIX_C_SOURCE
5223 make an error
5224 #endif],
5225         [cf_cv_posix_c_source=no],
5226         [cf_want_posix_source=no
5227          case .$cf_POSIX_C_SOURCE in
5228          (.[[12]]??*)
5229                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
5230                 ;;
5231          (.2)
5232                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
5233                 cf_want_posix_source=yes
5234                 ;;
5235          (.*)
5236                 cf_want_posix_source=yes
5237                 ;;
5238          esac
5239          if test "$cf_want_posix_source" = yes ; then
5240                 AC_TRY_COMPILE([#include <sys/types.h>],[
5241 #ifdef _POSIX_SOURCE
5242 make an error
5243 #endif],[],
5244                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
5245          fi
5246          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
5247          CFLAGS="$cf_trim_CFLAGS"
5248          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
5249          CF_MSG_LOG(if the second compile does not leave our definition intact error)
5250          AC_TRY_COMPILE([#include <sys/types.h>],[
5251 #ifndef _POSIX_C_SOURCE
5252 make an error
5253 #endif],,
5254          [cf_cv_posix_c_source=no])
5255          CFLAGS="$cf_save_CFLAGS"
5256          CPPFLAGS="$cf_save_CPPFLAGS"
5257         ])
5258 ])
5259
5260 if test "$cf_cv_posix_c_source" != no ; then
5261         CFLAGS="$cf_trim_CFLAGS"
5262         CPPFLAGS="$cf_trim_CPPFLAGS"
5263         CF_ADD_CFLAGS($cf_cv_posix_c_source)
5264 fi
5265
5266 ])dnl
5267 dnl ---------------------------------------------------------------------------
5268 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
5269 dnl ------------
5270 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
5271 dnl
5272 dnl $1 = symbol to test
5273 dnl $2 = value (if any) to use for a predefinition
5274 AC_DEFUN([CF_PREDEFINE],
5275 [
5276 AC_MSG_CHECKING(if we must define $1)
5277 AC_TRY_COMPILE([#include <sys/types.h>
5278 ],[
5279 #ifndef $1
5280 make an error
5281 #endif],[cf_result=no],[cf_result=yes])
5282 AC_MSG_RESULT($cf_result)
5283
5284 if test "$cf_result" = yes ; then
5285         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
5286 elif test "x$2" != "x" ; then
5287         AC_MSG_CHECKING(checking for compatible value versus $2)
5288         AC_TRY_COMPILE([#include <sys/types.h>
5289 ],[
5290 #if $1-$2 < 0
5291 make an error
5292 #endif],[cf_result=yes],[cf_result=no])
5293         AC_MSG_RESULT($cf_result)
5294         if test "$cf_result" = no ; then
5295                 # perhaps we can override it - try...
5296                 CPPFLAGS="$CPPFLAGS -D$1=$2"
5297         fi
5298 fi
5299 ])dnl
5300 dnl ---------------------------------------------------------------------------
5301 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
5302 dnl ------------
5303 dnl Append definitions and rules for the given programs to the subdirectory
5304 dnl Makefiles, and the recursion rule for the top-level Makefile.
5305 dnl
5306 dnl parameters
5307 dnl     $1 = script to run
5308 dnl     $2 = list of subdirectories
5309 dnl
5310 dnl variables
5311 dnl     $AWK
5312 AC_DEFUN([CF_PRG_RULES],
5313 [
5314 for cf_dir in $2
5315 do
5316         if test ! -d $srcdir/$cf_dir; then
5317                 continue
5318         elif test -f $srcdir/$cf_dir/programs; then
5319                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
5320         fi
5321 done
5322
5323 ])dnl
5324 dnl ---------------------------------------------------------------------------
5325 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
5326 dnl ----------
5327 dnl Check for archiver "ar".
5328 AC_DEFUN([CF_PROG_AR],[
5329 AC_CHECK_TOOL(AR, ar, ar)
5330 ])
5331 dnl ---------------------------------------------------------------------------
5332 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
5333 dnl -----------
5334 dnl Check for awk, ensure that the check found something.
5335 AC_DEFUN([CF_PROG_AWK],
5336 [
5337 AC_PROG_AWK
5338 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
5339 ])dnl
5340 dnl ---------------------------------------------------------------------------
5341 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
5342 dnl ----------
5343 dnl standard check for CC, plus followup sanity checks
5344 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
5345 AC_DEFUN([CF_PROG_CC],[
5346 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
5347 CF_GCC_VERSION
5348 CF_ACVERSION_CHECK(2.52,
5349         [AC_PROG_CC_STDC],
5350         [CF_ANSI_CC_REQD])
5351 CF_CC_ENV_FLAGS
5352 ])dnl
5353 dnl ---------------------------------------------------------------------------
5354 dnl CF_PROG_CC_C_O version: 4 updated: 2016/05/21 18:08:09
5355 dnl --------------
5356 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
5357 dnl the output file can be renamed, and allows for a shell variable that can
5358 dnl be used later.  The parameter is either CC or CXX.  The result is the
5359 dnl cache variable:
5360 dnl     $cf_cv_prog_CC_c_o
5361 dnl     $cf_cv_prog_CXX_c_o
5362 dnl
5363 dnl $1 = compiler
5364 dnl $2 = compiler options, if any
5365 AC_DEFUN([CF_PROG_CC_C_O],
5366 [AC_REQUIRE([AC_PROG_CC])dnl
5367 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
5368 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
5369 [
5370 cat > conftest.$ac_ext <<CF_EOF
5371 int main()
5372 {
5373         ${cf_cv_main_return:-return}(0);
5374 }
5375 CF_EOF
5376 # We do the test twice because some compilers refuse to overwrite an
5377 # existing .o file with -o, though they will create one.
5378 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
5379 if AC_TRY_EVAL(ac_try) &&
5380   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
5381 then
5382   eval cf_cv_prog_$1_c_o=yes
5383 else
5384   eval cf_cv_prog_$1_c_o=no
5385 fi
5386 rm -rf conftest*
5387 ])dnl
5388 if test $cf_cv_prog_$1_c_o = yes; then
5389   AC_MSG_RESULT([yes])
5390 else
5391   AC_MSG_RESULT([no])
5392 fi
5393 ])dnl
5394 dnl ---------------------------------------------------------------------------
5395 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
5396 dnl -------------
5397 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
5398 dnl This macro adds a check to ensure the script found something.
5399 AC_DEFUN([CF_PROG_EGREP],
5400 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
5401         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
5402                 then ac_cv_prog_egrep='grep -E'
5403                 else ac_cv_prog_egrep='egrep'
5404         fi])
5405         EGREP=$ac_cv_prog_egrep
5406         AC_SUBST([EGREP])
5407         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
5408 ])dnl
5409 dnl ---------------------------------------------------------------------------
5410 dnl CF_PROG_GNAT version: 3 updated: 2015/04/18 08:56:57
5411 dnl ------------
5412 dnl Check for gnatmake, ensure that it is complete.
5413 AC_DEFUN([CF_PROG_GNAT],[
5414 cf_ada_make=gnatmake
5415 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
5416 if test "$ac_cv_prog_gnat_exists" = no; then
5417         cf_ada_make=
5418         cf_cv_prog_gnat_correct=no
5419 else
5420         CF_GNAT_VERSION
5421         AC_CHECK_PROG(M4_exists, m4, yes, no)
5422         if test "$ac_cv_prog_M4_exists" = no; then
5423                 cf_cv_prog_gnat_correct=no
5424                 echo Ada95 binding required program m4 not found. Ada95 binding disabled.
5425         fi
5426         if test "$cf_cv_prog_gnat_correct" = yes; then
5427                 AC_MSG_CHECKING(if GNAT works)
5428                 CF_GNAT_TRY_RUN([procedure conftest;],
5429 [with Text_IO;
5430 with GNAT.OS_Lib;
5431 procedure conftest is
5432 begin
5433    Text_IO.Put ("Hello World");
5434    Text_IO.New_Line;
5435    GNAT.OS_Lib.OS_Exit (0);
5436 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
5437                 AC_MSG_RESULT($cf_cv_prog_gnat_correct)
5438         fi
5439 fi
5440
5441 AC_SUBST(cf_ada_make)
5442 ])dnl
5443 dnl ---------------------------------------------------------------------------
5444 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
5445 dnl ---------------
5446 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
5447 dnl misc/tabset install won't work properly.  Usually this happens only when
5448 dnl using the fallback mkinstalldirs script
5449 AC_DEFUN([CF_PROG_INSTALL],
5450 [AC_PROG_INSTALL
5451 case $INSTALL in
5452 (/*)
5453         ;;
5454 (*)
5455         CF_DIRNAME(cf_dir,$INSTALL)
5456         test -z "$cf_dir" && cf_dir=.
5457         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
5458         ;;
5459 esac
5460 ])dnl
5461 dnl ---------------------------------------------------------------------------
5462 dnl CF_PROG_LDCONFIG version: 5 updated: 2015/04/18 08:56:57
5463 dnl ----------------
5464 dnl Check for ldconfig, needed to fixup shared libraries that would be built
5465 dnl and then used in the install.
5466 AC_DEFUN([CF_PROG_LDCONFIG],[
5467 if test "$cross_compiling" = yes ; then
5468         LDCONFIG=:
5469 else
5470         case "$cf_cv_system_name" in
5471         (dragonfly*|mirbsd*|freebsd*)
5472                 test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
5473                 ;;
5474         (*) LDPATH=$PATH:/sbin:/usr/sbin
5475                 AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
5476                 ;;
5477         esac
5478 fi
5479 AC_SUBST(LDCONFIG)
5480 ])dnl
5481 dnl ---------------------------------------------------------------------------
5482 dnl CF_PROG_LINT version: 3 updated: 2016/05/22 15:25:54
5483 dnl ------------
5484 AC_DEFUN([CF_PROG_LINT],
5485 [
5486 AC_CHECK_PROGS(LINT, lint cppcheck splint)
5487 AC_SUBST(LINT_OPTS)
5488 ])dnl
5489 dnl ---------------------------------------------------------------------------
5490 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
5491 dnl ------------
5492 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
5493 dnl option if it is supported.
5494 AC_DEFUN([CF_PROG_LN_S],[
5495 AC_PROG_LN_S
5496 AC_MSG_CHECKING(if $LN_S -f options work)
5497
5498 rm -f conf$$.src conf$$dst
5499 echo >conf$$.dst
5500 echo first >conf$$.src
5501 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
5502         cf_prog_ln_sf=yes
5503 else
5504         cf_prog_ln_sf=no
5505 fi
5506 rm -f conf$$.dst conf$$src
5507 AC_MSG_RESULT($cf_prog_ln_sf)
5508
5509 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
5510 ])dnl
5511 dnl ---------------------------------------------------------------------------
5512 dnl CF_REGEX version: 12 updated: 2015/04/18 08:56:57
5513 dnl --------
5514 dnl Attempt to determine if we've got one of the flavors of regular-expression
5515 dnl code that we can support.
5516 AC_DEFUN([CF_REGEX],
5517 [
5518
5519 cf_regex_func=no
5520
5521 cf_regex_libs="regex re"
5522 case $host_os in
5523 (mingw*)
5524         cf_regex_libs="gnurx $cf_regex_libs"
5525         ;;
5526 esac
5527
5528 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
5529         for cf_regex_lib in $cf_regex_libs
5530         do
5531                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
5532                                 CF_ADD_LIB($cf_regex_lib)
5533                                 cf_regex_func=regcomp
5534                                 break])
5535         done
5536 ])
5537
5538 if test "$cf_regex_func" = no ; then
5539         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
5540                 AC_CHECK_LIB(gen,compile,[
5541                                 CF_ADD_LIB(gen)
5542                                 cf_regex_func=compile])])
5543 fi
5544
5545 if test "$cf_regex_func" = no ; then
5546         AC_MSG_WARN(cannot find regular expression library)
5547 fi
5548
5549 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
5550
5551 cf_cv_regex_hdrs=no
5552 case $cf_regex_func in
5553 (compile)
5554         for cf_regex_hdr in regexp.h regexpr.h
5555         do
5556                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
5557                         char *p = compile("", "", "", 0);
5558                         int x = step("", "");
5559                 ],[
5560                         cf_cv_regex_hdrs=$cf_regex_hdr
5561                         break
5562                 ])
5563         done
5564         ;;
5565 (*)
5566         for cf_regex_hdr in regex.h
5567         do
5568                 AC_TRY_LINK([#include <sys/types.h>
5569 #include <$cf_regex_hdr>],[
5570                         regex_t *p;
5571                         int x = regcomp(p, "", 0);
5572                         int y = regexec(p, "", 0, 0, 0);
5573                         regfree(p);
5574                 ],[
5575                         cf_cv_regex_hdrs=$cf_regex_hdr
5576                         break
5577                 ])
5578         done
5579         ;;
5580 esac
5581
5582 ])
5583
5584 case $cf_cv_regex_hdrs in
5585         (no)            AC_MSG_WARN(no regular expression header found) ;;
5586         (regex.h)       AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;;
5587         (regexp.h)      AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;;
5588         (regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
5589 esac
5590 ])dnl
5591 dnl ---------------------------------------------------------------------------
5592 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
5593 dnl ----------------
5594 dnl Remove all -U and -D options that refer to the given symbol from a list
5595 dnl of C compiler options.  This works around the problem that not all
5596 dnl compilers process -U and -D options from left-to-right, so a -U option
5597 dnl cannot be used to cancel the effect of a preceding -D option.
5598 dnl
5599 dnl $1 = target (which could be the same as the source variable)
5600 dnl $2 = source (including '$')
5601 dnl $3 = symbol to remove
5602 define([CF_REMOVE_DEFINE],
5603 [
5604 $1=`echo "$2" | \
5605         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
5606                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
5607 ])dnl
5608 dnl ---------------------------------------------------------------------------
5609 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
5610 dnl -------------
5611 dnl Remove the given library from the symbol
5612 dnl
5613 dnl $1 = target (which could be the same as the source variable)
5614 dnl $2 = source (including '$')
5615 dnl $3 = library to remove
5616 define([CF_REMOVE_LIB],
5617 [
5618 # remove $3 library from $2
5619 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5620 ])dnl
5621 dnl ---------------------------------------------------------------------------
5622 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
5623 dnl -------------
5624 AC_DEFUN([CF_RPATH_HACK],
5625 [
5626 AC_REQUIRE([CF_LD_RPATH_OPT])
5627 AC_MSG_CHECKING(for updated LDFLAGS)
5628 if test -n "$LD_RPATH_OPT" ; then
5629         AC_MSG_RESULT(maybe)
5630
5631         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5632         cf_rpath_list="/usr/lib /lib"
5633         if test "$cf_ldd_prog" != no
5634         then
5635                 cf_rpath_oops=
5636
5637 AC_TRY_LINK([#include <stdio.h>],
5638                 [printf("Hello");],
5639                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
5640                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
5641
5642                 # If we passed the link-test, but get a "not found" on a given library,
5643                 # this could be due to inept reconfiguration of gcc to make it only
5644                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
5645                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
5646                 # /usr/local libraries.
5647                 if test -n "$cf_rpath_oops"
5648                 then
5649                         for cf_rpath_src in $cf_rpath_oops
5650                         do
5651                                 for cf_rpath_dir in \
5652                                         /usr/local \
5653                                         /usr/pkg \
5654                                         /opt/sfw
5655                                 do
5656                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
5657                                         then
5658                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
5659                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
5660                                                 break
5661                                         fi
5662                                 done
5663                         done
5664                 fi
5665         fi
5666
5667         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5668
5669         CF_RPATH_HACK_2(LDFLAGS)
5670         CF_RPATH_HACK_2(LIBS)
5671
5672         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5673 else
5674         AC_MSG_RESULT(no)
5675 fi
5676 AC_SUBST(EXTRA_LDFLAGS)
5677 ])dnl
5678 dnl ---------------------------------------------------------------------------
5679 dnl CF_RPATH_HACK_2 version: 7 updated: 2015/04/12 15:39:00
5680 dnl ---------------
5681 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
5682 dnl EXTRA_LDFLAGS for each -L option found.
5683 dnl
5684 dnl $cf_rpath_list contains a list of directories to ignore.
5685 dnl
5686 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
5687 dnl      but LIBS often has misplaced -L options.
5688 AC_DEFUN([CF_RPATH_HACK_2],
5689 [
5690 CF_VERBOSE(...checking $1 [$]$1)
5691
5692 cf_rpath_dst=
5693 for cf_rpath_src in [$]$1
5694 do
5695         case $cf_rpath_src in
5696         (-L*)
5697
5698                 # check if this refers to a directory which we will ignore
5699                 cf_rpath_skip=no
5700                 if test -n "$cf_rpath_list"
5701                 then
5702                         for cf_rpath_item in $cf_rpath_list
5703                         do
5704                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
5705                                 then
5706                                         cf_rpath_skip=yes
5707                                         break
5708                                 fi
5709                         done
5710                 fi
5711
5712                 if test "$cf_rpath_skip" = no
5713                 then
5714                         # transform the option
5715                         if test "$LD_RPATH_OPT" = "-R " ; then
5716                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
5717                         else
5718                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
5719                         fi
5720
5721                         # if we have not already added this, add it now
5722                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
5723                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
5724                         then
5725                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
5726                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
5727                         fi
5728                 fi
5729                 ;;
5730         esac
5731         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
5732 done
5733 $1=$cf_rpath_dst
5734
5735 CF_VERBOSE(...checked $1 [$]$1)
5736 AC_SUBST(EXTRA_LDFLAGS)
5737 ])dnl
5738 dnl ---------------------------------------------------------------------------
5739 dnl CF_SHARED_OPTS version: 89 updated: 2015/08/15 18:38:59
5740 dnl --------------
5741 dnl --------------
5742 dnl Attempt to determine the appropriate CC/LD options for creating a shared
5743 dnl library.
5744 dnl
5745 dnl Notes:
5746 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
5747 dnl the build-tree, i.e., by making use of the libraries that are compiled in
5748 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
5749 dnl shared library since that can lead to unexpected results at runtime.
5750 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
5751 dnl libraries are compiled in ../../lib
5752 dnl
5753 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
5754 dnl to install symbolic links to the rel/abi versions of shared libraries.
5755 dnl
5756 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
5757 dnl version when making symbolic links.
5758 dnl
5759 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
5760 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
5761 dnl (ex: libncurses.so.<ver>).
5762 dnl
5763 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
5764 AC_DEFUN([CF_SHARED_OPTS],
5765 [
5766         AC_REQUIRE([CF_LD_RPATH_OPT])
5767         RM_SHARED_OPTS=
5768         LOCAL_LDFLAGS=
5769         LOCAL_LDFLAGS2=
5770         LD_SHARED_OPTS=
5771         INSTALL_LIB="-m 644"
5772         : ${rel_builddir:=.}
5773
5774         shlibdir=$libdir
5775         AC_SUBST(shlibdir)
5776
5777         MAKE_DLLS="#"
5778         AC_SUBST(MAKE_DLLS)
5779
5780         cf_cv_do_symlinks=no
5781         cf_ld_rpath_opt=
5782         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
5783
5784         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
5785         AC_ARG_WITH(shlib-version,
5786         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
5787         [test -z "$withval" && withval=auto
5788         case $withval in
5789         (yes)
5790                 cf_cv_shlib_version=auto
5791                 ;;
5792         (rel|abi|auto)
5793                 cf_cv_shlib_version=$withval
5794                 ;;
5795         (*)
5796                 AC_MSG_RESULT($withval)
5797                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
5798                 ;;
5799         esac
5800         ],[cf_cv_shlib_version=auto])
5801         AC_MSG_RESULT($cf_cv_shlib_version)
5802
5803         cf_cv_rm_so_locs=no
5804         cf_try_cflags=
5805
5806         # Some less-capable ports of gcc support only -fpic
5807         CC_SHARED_OPTS=
5808         if test "$GCC" = yes
5809         then
5810                 AC_MSG_CHECKING(which $CC option to use)
5811                 cf_save_CFLAGS="$CFLAGS"
5812                 for CC_SHARED_OPTS in -fPIC -fpic ''
5813                 do
5814                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
5815                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
5816                 done
5817                 AC_MSG_RESULT($CC_SHARED_OPTS)
5818                 CFLAGS="$cf_save_CFLAGS"
5819         fi
5820
5821         cf_cv_shlib_version_infix=no
5822
5823         case $cf_cv_system_name in
5824         (aix4.[3-9]*|aix[[5-7]]*)
5825                 if test "$GCC" = yes; then
5826                         CC_SHARED_OPTS='-Wl,-brtl'
5827                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5828                 else
5829                         CC_SHARED_OPTS='-brtl'
5830                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
5831                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5832                 fi
5833                 ;;
5834         (beos*)
5835                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
5836                 ;;
5837         (cygwin*)
5838                 CC_SHARED_OPTS=
5839                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5840                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5841                 cf_cv_shlib_version=cygdll
5842                 cf_cv_shlib_version_infix=cygdll
5843                 shlibdir=$bindir
5844                 MAKE_DLLS=
5845                 cat >mk_shared_lib.sh <<-CF_EOF
5846                 #!$SHELL
5847                 SHARED_LIB=\[$]1
5848                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5849                 shift
5850                 cat <<-EOF
5851                 Linking shared library
5852                 ** SHARED_LIB \[$]SHARED_LIB
5853                 ** IMPORT_LIB \[$]IMPORT_LIB
5854 EOF
5855                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5856 CF_EOF
5857                 chmod +x mk_shared_lib.sh
5858                 ;;
5859         (msys*)
5860                 CC_SHARED_OPTS=
5861                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5862                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5863                 cf_cv_shlib_version=msysdll
5864                 cf_cv_shlib_version_infix=msysdll
5865                 shlibdir=$bindir
5866                 MAKE_DLLS=
5867                 cat >mk_shared_lib.sh <<-CF_EOF
5868                 #!$SHELL
5869                 SHARED_LIB=\[$]1
5870                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5871                 shift
5872                 cat <<-EOF
5873                 Linking shared library
5874                 ** SHARED_LIB \[$]SHARED_LIB
5875                 ** IMPORT_LIB \[$]IMPORT_LIB
5876 EOF
5877                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5878 CF_EOF
5879                 chmod +x mk_shared_lib.sh
5880                 ;;
5881         (darwin*)
5882                 cf_try_cflags="no-cpp-precomp"
5883                 CC_SHARED_OPTS="-dynamic"
5884                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
5885                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
5886                 cf_cv_shlib_version_infix=yes
5887                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
5888                         cf_save_LDFLAGS=$LDFLAGS
5889                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5890                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
5891                                 LDFLAGS=$cf_save_LDFLAGS])
5892                 if test $cf_cv_ldflags_search_paths_first = yes; then
5893                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5894                 fi
5895                 ;;
5896         (hpux[[7-8]]*)
5897                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
5898                 if test "$GCC" != yes; then
5899                         CC_SHARED_OPTS='+Z'
5900                 fi
5901                 MK_SHARED_LIB='${LD} -b -o $[@]'
5902                 INSTALL_LIB="-m 555"
5903                 ;;
5904         (hpux*)
5905                 # (tested with gcc 2.7.2 -- I don't have c89)
5906                 if test "$GCC" = yes; then
5907                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
5908                 else
5909                         CC_SHARED_OPTS='+Z'
5910                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
5911                 fi
5912                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
5913                 # HP-UX shared libraries must be executable, and should be
5914                 # readonly to exploit a quirk in the memory manager.
5915                 INSTALL_LIB="-m 555"
5916                 ;;
5917         (interix*)
5918                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5919                 if test "$cf_cv_shlib_version" = rel; then
5920                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
5921                 else
5922                         cf_shared_soname='`basename $@`'
5923                 fi
5924                 CC_SHARED_OPTS=
5925                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
5926                 ;;
5927         (irix*)
5928                 if test "$cf_cv_enable_rpath" = yes ; then
5929                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5930                 fi
5931                 # tested with IRIX 5.2 and 'cc'.
5932                 if test "$GCC" != yes; then
5933                         CC_SHARED_OPTS='-KPIC'
5934                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
5935                 else
5936                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
5937                 fi
5938                 cf_cv_rm_so_locs=yes
5939                 ;;
5940         (linux*|gnu*|k*bsd*-gnu)
5941                 if test "$DFT_LWR_MODEL" = "shared" ; then
5942                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5943                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5944                 fi
5945                 if test "$cf_cv_enable_rpath" = yes ; then
5946                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5947                 fi
5948                 CF_SHARED_SONAME
5949                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5950                 ;;
5951         (mingw*)
5952                 cf_cv_shlib_version=mingw
5953                 cf_cv_shlib_version_infix=mingw
5954                 shlibdir=$bindir
5955                 MAKE_DLLS=
5956                 if test "$DFT_LWR_MODEL" = "shared" ; then
5957                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
5958                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5959                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
5960                 fi
5961                 CC_SHARED_OPTS=
5962                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5963                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5964                 cat >mk_shared_lib.sh <<-CF_EOF
5965                 #!$SHELL
5966                 SHARED_LIB=\[$]1
5967                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5968                 shift
5969                 cat <<-EOF
5970                 Linking shared library
5971                 ** SHARED_LIB \[$]SHARED_LIB
5972                 ** IMPORT_LIB \[$]IMPORT_LIB
5973 EOF
5974                 exec \[$]* -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5975 CF_EOF
5976                 chmod +x mk_shared_lib.sh
5977                 ;;
5978         (openbsd[[2-9]].*|mirbsd*)
5979                 if test "$DFT_LWR_MODEL" = "shared" ; then
5980                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5981                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5982                 fi
5983                 if test "$cf_cv_enable_rpath" = yes ; then
5984                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5985                 fi
5986                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5987                 CF_SHARED_SONAME
5988                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5989                 ;;
5990         (nto-qnx*|openbsd*|freebsd[[12]].*)
5991                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5992                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
5993                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5994                 ;;
5995         (dragonfly*|freebsd*)
5996                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5997                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5998                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5999                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
6000                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6001                 fi
6002                 CF_SHARED_SONAME
6003                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
6004                 ;;
6005         (netbsd*)
6006                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6007                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
6008                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
6009                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6010                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6011                         if test "$cf_cv_shlib_version" = auto; then
6012                         if test -f /usr/libexec/ld.elf_so; then
6013                                 cf_cv_shlib_version=abi
6014                         else
6015                                 cf_cv_shlib_version=rel
6016                         fi
6017                         fi
6018                         CF_SHARED_SONAME
6019                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
6020                 else
6021                         MK_SHARED_LIB='${CC} -Wl,-shared -Wl,-Bshareable -o $[@]'
6022                 fi
6023                 ;;
6024         (osf*|mls+*)
6025                 # tested with OSF/1 V3.2 and 'cc'
6026                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
6027                 # link with shared libs).
6028                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
6029                 case $host_os in
6030                 (osf4*)
6031                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
6032                         ;;
6033                 esac
6034                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
6035                 if test "$DFT_LWR_MODEL" = "shared" ; then
6036                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
6037                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6038                 fi
6039                 cf_cv_rm_so_locs=yes
6040                 ;;
6041         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
6042                 # tested with osr5.0.5
6043                 if test "$GCC" != yes; then
6044                         CC_SHARED_OPTS='-belf -KPIC'
6045                 fi
6046                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
6047                 if test "$cf_cv_enable_rpath" = yes ; then
6048                         # only way is to set LD_RUN_PATH but no switch for it
6049                         RUN_PATH=$libdir
6050                 fi
6051                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6052                 LINK_PROGS='LD_RUN_PATH=${libdir}'
6053                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
6054                 ;;
6055         (sunos4*)
6056                 # tested with SunOS 4.1.1 and gcc 2.7.0
6057                 if test "$GCC" != yes; then
6058                         CC_SHARED_OPTS='-KPIC'
6059                 fi
6060                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
6061                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6062                 ;;
6063         (solaris2*)
6064                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
6065                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
6066                 if test "$DFT_LWR_MODEL" = "shared" ; then
6067                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
6068                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6069                 fi
6070                 if test "$cf_cv_enable_rpath" = yes ; then
6071                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
6072                 fi
6073                 CF_SHARED_SONAME
6074                 if test "$GCC" != yes; then
6075                         cf_save_CFLAGS="$CFLAGS"
6076                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
6077                         do
6078                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
6079                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
6080                         done
6081                         CFLAGS="$cf_save_CFLAGS"
6082                         CC_SHARED_OPTS=$cf_shared_opts
6083                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
6084                 else
6085                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
6086                 fi
6087                 ;;
6088         (sysv5uw7*|unix_sv*)
6089                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
6090                 if test "$GCC" != yes; then
6091                         CC_SHARED_OPTS='-KPIC'
6092                 fi
6093                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
6094                 ;;
6095         (*)
6096                 CC_SHARED_OPTS='unknown'
6097                 MK_SHARED_LIB='echo unknown'
6098                 ;;
6099         esac
6100
6101         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
6102         case "$cf_cv_shlib_version" in
6103         (rel|abi)
6104                 case "$MK_SHARED_LIB" in
6105                 (*'-o $[@]')
6106                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
6107                         ;;
6108                 (*)
6109                         AC_MSG_WARN(ignored --with-shlib-version)
6110                         ;;
6111                 esac
6112                 ;;
6113         esac
6114
6115         if test -n "$cf_try_cflags"
6116         then
6117 cat > conftest.$ac_ext <<EOF
6118 #line __oline__ "${as_me:-configure}"
6119 #include <stdio.h>
6120 int main(int argc, char *argv[[]])
6121 {
6122         printf("hello\n");
6123         return (argv[[argc-1]] == 0) ;
6124 }
6125 EOF
6126                 cf_save_CFLAGS="$CFLAGS"
6127                 for cf_opt in $cf_try_cflags
6128                 do
6129                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
6130                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
6131                         if AC_TRY_EVAL(ac_compile); then
6132                                 AC_MSG_RESULT(yes)
6133                                 cf_save_CFLAGS="$CFLAGS"
6134                         else
6135                                 AC_MSG_RESULT(no)
6136                         fi
6137                 done
6138                 CFLAGS="$cf_save_CFLAGS"
6139         fi
6140
6141
6142         # RPATH_LIST is a colon-separated list of directories
6143         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
6144         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
6145
6146         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
6147
6148         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
6149         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
6150
6151         AC_SUBST(CC_SHARED_OPTS)
6152         AC_SUBST(LD_RPATH_OPT)
6153         AC_SUBST(LD_SHARED_OPTS)
6154         AC_SUBST(MK_SHARED_LIB)
6155         AC_SUBST(RM_SHARED_OPTS)
6156
6157         AC_SUBST(LINK_PROGS)
6158         AC_SUBST(LINK_TESTS)
6159
6160         AC_SUBST(EXTRA_LDFLAGS)
6161         AC_SUBST(LOCAL_LDFLAGS)
6162         AC_SUBST(LOCAL_LDFLAGS2)
6163
6164         AC_SUBST(INSTALL_LIB)
6165         AC_SUBST(RPATH_LIST)
6166 ])dnl
6167 dnl ---------------------------------------------------------------------------
6168 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
6169 dnl ----------------
6170 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
6171 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
6172 dnl option.
6173 dnl
6174 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
6175 dnl If missing, use "rel".
6176 define([CF_SHARED_SONAME],
6177 [
6178         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
6179         if test "$cf_cv_shlib_version" = rel; then
6180                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
6181         else
6182                 cf_cv_shared_soname='`basename $[@]`'
6183         fi
6184 ])
6185 dnl ---------------------------------------------------------------------------
6186 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
6187 dnl -----------
6188 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
6189 dnl programs need this test).
6190 dnl
6191 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
6192 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
6193 dnl winsize declaration is left alone - we may revisit this if Apple choose to
6194 dnl break that part of the interface as well.
6195 AC_DEFUN([CF_SIGWINCH],
6196 [
6197 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
6198         AC_TRY_COMPILE([
6199 #include <sys/types.h>
6200 #include <sys/signal.h>
6201 ],[int x = SIGWINCH],
6202         [cf_cv_define_sigwinch=yes],
6203         [AC_TRY_COMPILE([
6204 #undef _XOPEN_SOURCE
6205 #undef _POSIX_SOURCE
6206 #undef _POSIX_C_SOURCE
6207 #include <sys/types.h>
6208 #include <sys/signal.h>
6209 ],[int x = SIGWINCH],
6210         [cf_cv_define_sigwinch=maybe],
6211         [cf_cv_define_sigwinch=no])
6212 ])
6213 ])
6214
6215 if test "$cf_cv_define_sigwinch" = maybe ; then
6216 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
6217 cf_cv_fixup_sigwinch=unknown
6218 cf_sigwinch=32
6219 while test $cf_sigwinch != 1
6220 do
6221         AC_TRY_COMPILE([
6222 #undef _XOPEN_SOURCE
6223 #undef _POSIX_SOURCE
6224 #undef _POSIX_C_SOURCE
6225 #include <sys/types.h>
6226 #include <sys/signal.h>
6227 ],[
6228 #if SIGWINCH != $cf_sigwinch
6229 make an error
6230 #endif
6231 int x = SIGWINCH],
6232         [cf_cv_fixup_sigwinch=$cf_sigwinch
6233          break])
6234
6235 cf_sigwinch=`expr $cf_sigwinch - 1`
6236 done
6237 ])
6238
6239         if test "$cf_cv_fixup_sigwinch" != unknown ; then
6240                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
6241         fi
6242 fi
6243 ])dnl
6244 dnl ---------------------------------------------------------------------------
6245 dnl CF_SIG_ATOMIC_T version: 3 updated: 2012/10/04 20:12:20
6246 dnl ---------------
6247 dnl signal handler, but there are some gcc depedencies in that recommendation.
6248 dnl Try anyway.
6249 AC_DEFUN([CF_SIG_ATOMIC_T],
6250 [
6251 AC_MSG_CHECKING(for signal global datatype)
6252 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
6253         for cf_type in \
6254                 "volatile sig_atomic_t" \
6255                 "sig_atomic_t" \
6256                 "int"
6257         do
6258         AC_TRY_COMPILE([
6259 #include <sys/types.h>
6260 #include <signal.h>
6261 #include <stdio.h>
6262
6263 extern $cf_type x;
6264 $cf_type x;
6265 static void handler(int sig)
6266 {
6267         x = 5;
6268 }],
6269                 [signal(SIGINT, handler);
6270                  x = 1],
6271                 [cf_cv_sig_atomic_t=$cf_type],
6272                 [cf_cv_sig_atomic_t=no])
6273                 test "$cf_cv_sig_atomic_t" != no && break
6274         done
6275         ])
6276 AC_MSG_RESULT($cf_cv_sig_atomic_t)
6277 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
6278 ])dnl
6279 dnl ---------------------------------------------------------------------------
6280 dnl CF_SIZECHANGE version: 11 updated: 2015/04/18 08:56:57
6281 dnl -------------
6282 dnl Check for definitions & structures needed for window size-changing
6283 dnl FIXME: check that this works with "snake" (HP-UX 10.x)
6284 AC_DEFUN([CF_SIZECHANGE],
6285 [
6286 AC_REQUIRE([CF_STRUCT_TERMIOS])
6287 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
6288         cf_cv_sizechange=unknown
6289         cf_save_CPPFLAGS="$CPPFLAGS"
6290
6291 for cf_opts in "" "NEED_PTEM_H"
6292 do
6293
6294         CPPFLAGS="$cf_save_CPPFLAGS"
6295         test -n "$cf_opts" && CPPFLAGS="$CPPFLAGS -D$cf_opts"
6296         AC_TRY_COMPILE([#include <sys/types.h>
6297 #ifdef HAVE_TERMIOS_H
6298 #include <termios.h>
6299 #else
6300 #ifdef HAVE_TERMIO_H
6301 #include <termio.h>
6302 #endif
6303 #endif
6304 #ifdef NEED_PTEM_H
6305 /* This is a workaround for SCO:  they neglected to define struct winsize in
6306  * termios.h -- it's only in termio.h and ptem.h
6307  */
6308 #include        <sys/stream.h>
6309 #include        <sys/ptem.h>
6310 #endif
6311 #if !defined(sun) || !defined(HAVE_TERMIOS_H)
6312 #include <sys/ioctl.h>
6313 #endif
6314 ],[
6315 #ifdef TIOCGSIZE
6316         struct ttysize win;     /* FIXME: what system is this? */
6317         int y = win.ts_lines;
6318         int x = win.ts_cols;
6319 #else
6320 #ifdef TIOCGWINSZ
6321         struct winsize win;
6322         int y = win.ws_row;
6323         int x = win.ws_col;
6324 #else
6325         no TIOCGSIZE or TIOCGWINSZ
6326 #endif /* TIOCGWINSZ */
6327 #endif /* TIOCGSIZE */
6328         ],
6329         [cf_cv_sizechange=yes],
6330         [cf_cv_sizechange=no])
6331
6332         CPPFLAGS="$cf_save_CPPFLAGS"
6333         if test "$cf_cv_sizechange" = yes ; then
6334                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
6335                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
6336                 break
6337         fi
6338 done
6339 ])
6340 if test "$cf_cv_sizechange" != no ; then
6341         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechar declarations are provided])
6342         case $cf_cv_sizechange in
6343         (NEED*)
6344                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
6345                 ;;
6346         esac
6347 fi
6348 ])dnl
6349 dnl ---------------------------------------------------------------------------
6350 dnl CF_SRC_MODULES version: 29 updated: 2015/04/12 11:42:01
6351 dnl --------------
6352 dnl For each parameter, test if the source-directory exists, and if it contains
6353 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
6354 dnl use in CF_LIB_RULES.
6355 dnl
6356 dnl This uses the configured value to make the lists SRC_SUBDIRS and
6357 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
6358 AC_DEFUN([CF_SRC_MODULES],
6359 [
6360 AC_MSG_CHECKING(for src modules)
6361
6362 # dependencies and linker-arguments for test-programs
6363 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
6364 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
6365 if test "$DFT_LWR_MODEL" = "libtool"; then
6366         TEST_ARGS="${TEST_DEPS}"
6367         TEST_ARG2="${TEST_DEP2}"
6368 else
6369         TEST_ARGS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
6370         TEST_ARG2="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARG2"
6371 fi
6372
6373 PC_MODULES_TO_MAKE="ncurses${USE_ARG_SUFFIX}"
6374 cf_cv_src_modules=
6375 for cf_dir in $1
6376 do
6377         if test -f $srcdir/$cf_dir/modules; then
6378
6379                 # We may/may not have tack in the distribution, though the
6380                 # makefile is.
6381                 if test $cf_dir = tack ; then
6382                         if test ! -f $srcdir/${cf_dir}/${cf_dir}.h; then
6383                                 continue
6384                         fi
6385                 fi
6386
6387                 if test -z "$cf_cv_src_modules"; then
6388                         cf_cv_src_modules=$cf_dir
6389                 else
6390                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
6391                 fi
6392
6393                 # Make the ncurses_cfg.h file record the library interface files as
6394                 # well.  These are header files that are the same name as their
6395                 # directory.  Ncurses is the only library that does not follow
6396                 # that pattern.
6397                 if test $cf_dir = tack ; then
6398                         continue
6399                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
6400                         CF_UPPER(cf_have_include,$cf_dir)
6401                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
6402                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
6403                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
6404                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
6405                         if test "$DFT_LWR_MODEL" = "libtool"; then
6406                                 TEST_ARGS="${TEST_DEPS}"
6407                                 TEST_ARG2="${TEST_DEP2}"
6408                         else
6409                                 TEST_ARGS="-l${cf_dir}${USE_ARG_SUFFIX} $TEST_ARGS"
6410                                 TEST_ARG2="-l${cf_dir}${USE_ARG_SUFFIX} $TEST_ARG2"
6411                         fi
6412                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${USE_ARG_SUFFIX}"
6413                 fi
6414         fi
6415 done
6416 AC_MSG_RESULT($cf_cv_src_modules)
6417
6418 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
6419 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
6420
6421 AC_SUBST(TEST_ARGS)
6422 AC_SUBST(TEST_DEPS)
6423
6424 AC_SUBST(TEST_ARG2)
6425 AC_SUBST(TEST_DEP2)
6426
6427 SRC_SUBDIRS=
6428 if test "x$cf_with_manpages" != xno ; then
6429         SRC_SUBDIRS="$SRC_SUBDIRS man"
6430 fi
6431 SRC_SUBDIRS="$SRC_SUBDIRS include"
6432 for cf_dir in $cf_cv_src_modules
6433 do
6434         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
6435 done
6436 if test "x$cf_with_tests" != "xno" ; then
6437         SRC_SUBDIRS="$SRC_SUBDIRS test"
6438 fi
6439 # always make this, to install the ncurses-config script
6440 SRC_SUBDIRS="$SRC_SUBDIRS misc"
6441 if test "$cf_with_cxx_binding" != no; then
6442         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${USE_ARG_SUFFIX}"
6443         SRC_SUBDIRS="$SRC_SUBDIRS c++"
6444 fi
6445
6446 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
6447 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
6448
6449 AC_SUBST(PC_MODULES_TO_MAKE)
6450
6451 ADA_SUBDIRS=
6452 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
6453         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
6454         ADA_SUBDIRS="gen src"
6455         if test "x$cf_with_tests" != "xno" ; then
6456                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
6457         fi
6458 fi
6459
6460 SUB_MAKEFILES=
6461 for cf_dir in $SRC_SUBDIRS
6462 do
6463         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
6464 done
6465
6466 if test -n "$ADA_SUBDIRS"; then
6467         for cf_dir in $ADA_SUBDIRS
6468         do
6469                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
6470         done
6471         AC_SUBST(ADA_SUBDIRS)
6472 fi
6473 ])dnl
6474 dnl ---------------------------------------------------------------------------
6475 dnl CF_STDCPP_LIBRARY version: 11 updated: 2015/10/17 19:03:33
6476 dnl -----------------
6477 dnl Check for -lstdc++, which is GNU's standard C++ library.
6478 dnl If $CXXLIBS is set, add that to the libraries used for test-linking.
6479 dnl If -lstdc++ was not already added to $LIBS or $CXXLIBS, and is needed,
6480 dnl add it to $CXXLIBS.
6481 AC_DEFUN([CF_STDCPP_LIBRARY],
6482 [
6483 if test -n "$GXX" ; then
6484
6485         cf_save="$LIBS"
6486         LIBS="$LIBS $CXXLIBS"
6487         AC_MSG_CHECKING(if we already have C++ library)
6488         AC_TRY_LINK([
6489                         #include <iostream>],[
6490                         std::cout << "Hello World!" << std::endl;],
6491                 [cf_have_libstdcpp=yes],
6492                 [cf_have_libstdcpp=no])
6493         AC_MSG_RESULT($cf_have_libstdcpp)
6494         LIBS="$cf_save"
6495
6496         if test $cf_have_libstdcpp != yes
6497         then
6498                 case $cf_cv_system_name in
6499                 (os2*)
6500                         if test -z "`g++ -dM -E - < /dev/null | grep __KLIBC__`"; then
6501                                 cf_stdcpp_libname=stdcpp
6502                         else
6503                                 cf_stdcpp_libname=stdc++
6504                         fi
6505                         ;;
6506                 (*)
6507                         cf_stdcpp_libname=stdc++
6508                         ;;
6509                 esac
6510
6511                 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
6512                         cf_save="$LIBS"
6513                         LIBS="$LIBS $CXXLIBS"
6514                         CF_ADD_LIB($cf_stdcpp_libname)
6515                 AC_TRY_LINK([
6516                                 #include <iostream>],[
6517                                 std::cout << "Hello World!" << std::endl;],
6518                         [cf_cv_libstdcpp=yes],
6519                         [cf_cv_libstdcpp=no])
6520                         LIBS="$cf_save"
6521                 ])
6522                 test "$cf_cv_libstdcpp" = yes && { CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS) }
6523         fi
6524 fi
6525 ])dnl
6526 dnl ---------------------------------------------------------------------------
6527 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
6528 dnl --------------
6529 dnl     Remove "-g" option from the compiler options
6530 AC_DEFUN([CF_STRIP_G_OPT],
6531 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
6532 dnl ---------------------------------------------------------------------------
6533 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
6534 dnl -------------------
6535 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
6536 dnl do this if we've found the sigaction function.
6537 AC_DEFUN([CF_STRUCT_SIGACTION],[
6538 AC_REQUIRE([CF_XOPEN_SOURCE])
6539
6540 if test "$ac_cv_func_sigaction" = yes; then
6541 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
6542 AC_TRY_COMPILE([
6543 #include <sys/types.h>
6544 #include <signal.h>],
6545         [struct sigaction act],
6546         [sigact_bad=no],
6547         [
6548 AC_TRY_COMPILE([
6549 #define _POSIX_SOURCE
6550 #include <sys/types.h>
6551 #include <signal.h>],
6552         [struct sigaction act],
6553         [sigact_bad=yes
6554          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
6555          [sigact_bad=unknown])])
6556 AC_MSG_RESULT($sigact_bad)
6557 fi
6558 ])dnl
6559 dnl ---------------------------------------------------------------------------
6560 dnl CF_STRUCT_TERMIOS version: 8 updated: 2015/04/15 19:08:48
6561 dnl -----------------
6562 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
6563 AC_DEFUN([CF_STRUCT_TERMIOS],[
6564 AC_REQUIRE([CF_XOPEN_SOURCE])
6565
6566 AC_CHECK_HEADERS( \
6567 termio.h \
6568 termios.h \
6569 unistd.h \
6570 )
6571
6572 if test "$ISC" = yes ; then
6573         AC_CHECK_HEADERS( sys/termio.h )
6574 fi
6575 if test "$ac_cv_header_termios_h" = yes ; then
6576         case "$CFLAGS $CPPFLAGS" in
6577         (*-D_POSIX_SOURCE*)
6578                 termios_bad=dunno ;;
6579         (*)     termios_bad=maybe ;;
6580         esac
6581         if test "$termios_bad" = maybe ; then
6582         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
6583         AC_TRY_COMPILE([#include <termios.h>],
6584                 [struct termios foo; int x = foo.c_iflag],
6585                 termios_bad=no, [
6586                 AC_TRY_COMPILE([
6587 #define _POSIX_SOURCE
6588 #include <termios.h>],
6589                         [struct termios foo; int x = foo.c_iflag],
6590                         termios_bad=unknown,
6591                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
6592                         ])
6593         AC_MSG_RESULT($termios_bad)
6594         fi
6595 fi
6596 ])dnl
6597 dnl ---------------------------------------------------------------------------
6598 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
6599 dnl --------------
6600 dnl Construct a search-list for a nonstandard header/lib-file
6601 dnl     $1 = the variable to return as result
6602 dnl     $2 = the package name
6603 dnl     $3 = the subdirectory, e.g., bin, include or lib
6604 AC_DEFUN([CF_SUBDIR_PATH],
6605 [
6606 $1=
6607
6608 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
6609
6610 for cf_subdir_prefix in \
6611         /usr \
6612         /usr/local \
6613         /usr/pkg \
6614         /opt \
6615         /opt/local \
6616         [$]HOME
6617 do
6618         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
6619 done
6620 ])dnl
6621 dnl ---------------------------------------------------------------------------
6622 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
6623 dnl -----------
6624 dnl     Shorthand macro for substituting things that the user may override
6625 dnl     with an environment variable.
6626 dnl
6627 dnl     $1 = condition to pass to "test"
6628 dnl     $2 = environment variable
6629 dnl     $3 = value if the test succeeds
6630 dnl     $4 = value if the test fails
6631 AC_DEFUN([CF_SUBST_IF],
6632 [
6633 if test $1 ; then
6634         $2=$3
6635 ifelse($4,,,[else
6636         $2=$4])
6637 fi
6638 AC_SUBST($2)
6639 ])dnl
6640 dnl ---------------------------------------------------------------------------
6641 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
6642 dnl ------------------------
6643 dnl Get the version-number for use in shared-library naming, etc.
6644 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
6645 [
6646 AC_REQUIRE([CF_PROG_EGREP])
6647 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6648 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6649 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6650 cf_cv_abi_version=${NCURSES_MAJOR}
6651 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
6652 dnl Show the computed version, for logging
6653 cf_cv_timestamp=`date`
6654 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
6655 dnl We need these values in the generated headers
6656 AC_SUBST(NCURSES_MAJOR)
6657 AC_SUBST(NCURSES_MINOR)
6658 AC_SUBST(NCURSES_PATCH)
6659 dnl We need these values in the generated makefiles
6660 AC_SUBST(cf_cv_rel_version)
6661 AC_SUBST(cf_cv_abi_version)
6662 AC_SUBST(cf_cv_builtin_bool)
6663 AC_SUBST(cf_cv_header_stdbool_h)
6664 AC_SUBST(cf_cv_type_of_bool)dnl
6665 ])dnl
6666 dnl ---------------------------------------------------------------------------
6667 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
6668 dnl ------------------
6669 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
6670 dnl older SCO configurations.
6671 AC_DEFUN([CF_SYS_TIME_SELECT],
6672 [
6673 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
6674 AC_CACHE_VAL(cf_cv_sys_time_select,[
6675 AC_TRY_COMPILE([
6676 #include <sys/types.h>
6677 #ifdef HAVE_SYS_TIME_H
6678 #include <sys/time.h>
6679 #endif
6680 #ifdef HAVE_SYS_SELECT_H
6681 #include <sys/select.h>
6682 #endif
6683 ],[],[cf_cv_sys_time_select=yes],
6684          [cf_cv_sys_time_select=no])
6685          ])
6686 AC_MSG_RESULT($cf_cv_sys_time_select)
6687 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
6688 ])dnl
6689 dnl ---------------------------------------------------------------------------
6690 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
6691 dnl ---------------
6692 dnl Define a top_builddir symbol, for applications that need an absolute path.
6693 AC_DEFUN([CF_TOP_BUILDDIR],
6694 [
6695 top_builddir=ifelse($1,,`pwd`,$1)
6696 AC_SUBST(top_builddir)
6697 ])dnl
6698 dnl ---------------------------------------------------------------------------
6699 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
6700 dnl -------------------
6701 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
6702 dnl can define it successfully.
6703 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
6704 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
6705         AC_TRY_COMPILE([
6706 #include <stdlib.h>
6707 #include <string.h>
6708 #include <sys/types.h>
6709 ],[
6710 #ifndef _XOPEN_SOURCE
6711 make an error
6712 #endif],
6713         [cf_cv_xopen_source=no],
6714         [cf_save="$CPPFLAGS"
6715          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6716          AC_TRY_COMPILE([
6717 #include <stdlib.h>
6718 #include <string.h>
6719 #include <sys/types.h>
6720 ],[
6721 #ifdef _XOPEN_SOURCE
6722 make an error
6723 #endif],
6724         [cf_cv_xopen_source=no],
6725         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
6726         CPPFLAGS="$cf_save"
6727         ])
6728 ])
6729
6730 if test "$cf_cv_xopen_source" != no ; then
6731         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
6732         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
6733         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
6734         CF_ADD_CFLAGS($cf_temp_xopen_source)
6735 fi
6736 ])
6737 dnl ---------------------------------------------------------------------------
6738 dnl CF_TYPEOF_CHTYPE version: 9 updated: 2012/10/06 17:56:13
6739 dnl ----------------
6740 dnl Determine the type we should use for chtype (and attr_t, which is treated
6741 dnl as the same thing).  We want around 32 bits, so on most machines want a
6742 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
6743 dnl wide characters, we have to have a type compatible with that, as well.
6744 AC_DEFUN([CF_TYPEOF_CHTYPE],
6745 [
6746 AC_MSG_CHECKING([for type of chtype])
6747 AC_CACHE_VAL(cf_cv_typeof_chtype,[
6748                 AC_TRY_RUN([
6749 #define WANT_BITS 31
6750 #include <stdio.h>
6751 int main()
6752 {
6753         FILE *fp = fopen("cf_test.out", "w");
6754         if (fp != 0) {
6755                 char *result = "long";
6756                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
6757                         int n;
6758                         unsigned int x, y;
6759                         for (n = 0; n < WANT_BITS; n++) {
6760                                 x = (1 << n);
6761                                 y = (x >> n);
6762                                 if (y != 1 || x == 0) {
6763                                         x = 0;
6764                                         break;
6765                                 }
6766                         }
6767                         /*
6768                          * If x is nonzero, an int is big enough for the bits
6769                          * that we want.
6770                          */
6771                         result = (x != 0) ? "int" : "long";
6772                 }
6773                 fputs(result, fp);
6774                 fclose(fp);
6775         }
6776         ${cf_cv_main_return:-return}(0);
6777 }
6778                 ],
6779                 [cf_cv_typeof_chtype=`cat cf_test.out`],
6780                 [cf_cv_typeof_chtype=long],
6781                 [cf_cv_typeof_chtype=long])
6782                 rm -f cf_test.out
6783         ])
6784 AC_MSG_RESULT($cf_cv_typeof_chtype)
6785
6786 AC_SUBST(cf_cv_typeof_chtype)
6787 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
6788 ])dnl
6789 dnl ---------------------------------------------------------------------------
6790 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
6791 dnl -----------------
6792 dnl
6793 AC_DEFUN([CF_TYPE_SIGACTION],
6794 [
6795 AC_MSG_CHECKING([for type sigaction_t])
6796 AC_CACHE_VAL(cf_cv_type_sigaction,[
6797         AC_TRY_COMPILE([
6798 #include <signal.h>],
6799                 [sigaction_t x],
6800                 [cf_cv_type_sigaction=yes],
6801                 [cf_cv_type_sigaction=no])])
6802 AC_MSG_RESULT($cf_cv_type_sigaction)
6803 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
6804 ])dnl
6805 dnl ---------------------------------------------------------------------------
6806 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
6807 dnl --------------------
6808 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
6809 dnl won't, but they're still there.
6810 AC_DEFUN([CF_UNSIGNED_LITERALS],
6811 [
6812 AC_MSG_CHECKING([if unsigned literals are legal])
6813 AC_CACHE_VAL(cf_cv_unsigned_literals,[
6814         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
6815                 [cf_cv_unsigned_literals=yes],
6816                 [cf_cv_unsigned_literals=no])
6817         ])
6818 AC_MSG_RESULT($cf_cv_unsigned_literals)
6819 ])dnl
6820 dnl ---------------------------------------------------------------------------
6821 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
6822 dnl --------
6823 dnl Make an uppercase version of a variable
6824 dnl $1=uppercase($2)
6825 AC_DEFUN([CF_UPPER],
6826 [
6827 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6828 ])dnl
6829 dnl ---------------------------------------------------------------------------
6830 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
6831 dnl -----------
6832 dnl Check for multibyte support, and if not found, utf8 compatibility library
6833 AC_DEFUN([CF_UTF8_LIB],
6834 [
6835 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
6836         cf_save_LIBS="$LIBS"
6837         AC_TRY_LINK([
6838 #include <stdlib.h>],[putwc(0,0);],
6839         [cf_cv_utf8_lib=yes],
6840         [CF_FIND_LINKAGE([
6841 #include <libutf8.h>],[putwc(0,0);],utf8,
6842                 [cf_cv_utf8_lib=add-on],
6843                 [cf_cv_utf8_lib=no])
6844 ])])
6845
6846 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
6847 # ncurses/ncursesw:
6848 if test "$cf_cv_utf8_lib" = "add-on" ; then
6849         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
6850         CF_ADD_INCDIR($cf_cv_header_path_utf8)
6851         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
6852         CF_ADD_LIBS($cf_cv_library_file_utf8)
6853 fi
6854 ])dnl
6855 dnl ---------------------------------------------------------------------------
6856 dnl CF_VA_COPY version: 3 updated: 2012/10/06 11:17:15
6857 dnl ----------
6858 dnl check for va_copy, part of stdarg.h
6859 dnl Also, workaround for glibc's __va_copy, by checking for both.
6860 AC_DEFUN([CF_VA_COPY],[
6861 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
6862 AC_TRY_LINK([
6863 #include <stdarg.h>
6864 ],[
6865         static va_list dst;
6866         static va_list src;
6867         va_copy(dst, src)],
6868         cf_cv_have_va_copy=yes,
6869         cf_cv_have_va_copy=no)])
6870
6871 test "$cf_cv_have_va_copy" = yes && AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
6872
6873 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
6874 AC_TRY_LINK([
6875 #include <stdarg.h>
6876 ],[
6877         static va_list dst;
6878         static va_list src;
6879         __va_copy(dst, src)],
6880         cf_cv_have___va_copy=yes,
6881         cf_cv_have___va_copy=no)])
6882
6883 test "$cf_cv_have___va_copy" = yes && AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
6884 ])
6885 dnl ---------------------------------------------------------------------------
6886 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
6887 dnl ----------
6888 dnl Use AC_VERBOSE w/o the warnings
6889 AC_DEFUN([CF_VERBOSE],
6890 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
6891 CF_MSG_LOG([$1])
6892 ])dnl
6893 dnl ---------------------------------------------------------------------------
6894 dnl CF_VERSION_INFO version: 7 updated: 2015/04/17 21:13:04
6895 dnl ---------------
6896 dnl Define several useful symbols derived from the VERSION file.  A separate
6897 dnl file is preferred to embedding the version numbers in various scripts.
6898 dnl (automake is a textbook-example of why the latter is a bad idea, but there
6899 dnl are others).
6900 dnl
6901 dnl The file contents are:
6902 dnl     libtool-version release-version patch-version
6903 dnl or
6904 dnl     release-version
6905 dnl where
6906 dnl     libtool-version (see ?) consists of 3 integers separated by '.'
6907 dnl     release-version consists of a major version and minor version
6908 dnl             separated by '.', optionally followed by a patch-version
6909 dnl             separated by '-'.  The minor version need not be an
6910 dnl             integer (but it is preferred).
6911 dnl     patch-version is an integer in the form yyyymmdd, so ifdef's and
6912 dnl             scripts can easily compare versions.
6913 dnl
6914 dnl If libtool is used, the first form is required, since CF_WITH_LIBTOOL
6915 dnl simply extracts the first field using 'cut -f1'.
6916 dnl
6917 dnl Optional parameters:
6918 dnl $1 = internal name for package
6919 dnl $2 = external name for package
6920 AC_DEFUN([CF_VERSION_INFO],
6921 [
6922 if test -f $srcdir/VERSION ; then
6923         AC_MSG_CHECKING(for package version)
6924
6925         # if there are not enough fields, cut returns the last one...
6926         cf_field1=`sed -e '2,$d' $srcdir/VERSION|cut -f1`
6927         cf_field2=`sed -e '2,$d' $srcdir/VERSION|cut -f2`
6928         cf_field3=`sed -e '2,$d' $srcdir/VERSION|cut -f3`
6929
6930         # this is how CF_BUNDLED_INTL uses $VERSION:
6931         VERSION="$cf_field1"
6932
6933         VERSION_MAJOR=`echo "$cf_field2" | sed -e 's/\..*//'`
6934         test -z "$VERSION_MAJOR" && AC_MSG_ERROR(missing major-version)
6935
6936         VERSION_MINOR=`echo "$cf_field2" | sed -e 's/^[[^.]]*\.//' -e 's/-.*//'`
6937         test -z "$VERSION_MINOR" && AC_MSG_ERROR(missing minor-version)
6938
6939         AC_MSG_RESULT(${VERSION_MAJOR}.${VERSION_MINOR})
6940
6941         AC_MSG_CHECKING(for package patch date)
6942         VERSION_PATCH=`echo "$cf_field3" | sed -e 's/^[[^-]]*-//'`
6943         case .$VERSION_PATCH in
6944         (.)
6945                 AC_MSG_ERROR(missing patch-date $VERSION_PATCH)
6946                 ;;
6947         (.[[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]])
6948                 ;;
6949         (*)
6950                 AC_MSG_ERROR(illegal patch-date $VERSION_PATCH)
6951                 ;;
6952         esac
6953         AC_MSG_RESULT($VERSION_PATCH)
6954 else
6955         AC_MSG_ERROR(did not find $srcdir/VERSION)
6956 fi
6957
6958 # show the actual data that we have for versions:
6959 CF_VERBOSE(ABI VERSION $VERSION)
6960 CF_VERBOSE(VERSION_MAJOR $VERSION_MAJOR)
6961 CF_VERBOSE(VERSION_MINOR $VERSION_MINOR)
6962 CF_VERBOSE(VERSION_PATCH $VERSION_PATCH)
6963
6964 AC_SUBST(VERSION)
6965 AC_SUBST(VERSION_MAJOR)
6966 AC_SUBST(VERSION_MINOR)
6967 AC_SUBST(VERSION_PATCH)
6968
6969 dnl if a package name is given, define its corresponding version info.  We
6970 dnl need the package name to ensure that the defined symbols are unique.
6971 ifelse($1,,,[
6972         cf_PACKAGE=$1
6973         PACKAGE=ifelse($2,,$1,$2)
6974         AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",[Define to the package-name])
6975         AC_SUBST(PACKAGE)
6976         CF_UPPER(cf_PACKAGE,$cf_PACKAGE)
6977         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_VERSION,"${VERSION_MAJOR}.${VERSION_MINOR}")
6978         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_PATCHDATE,${VERSION_PATCH})
6979 ])
6980 ])dnl
6981 dnl ---------------------------------------------------------------------------
6982 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
6983 dnl -------------
6984 dnl Check if type wide-character type $1 is declared, and if so, which header
6985 dnl file is needed.  The second parameter is used to set a shell variable when
6986 dnl the type is not found.  The first parameter sets a shell variable for the
6987 dnl opposite sense.
6988 AC_DEFUN([CF_WCHAR_TYPE],
6989 [
6990 # This is needed on Tru64 5.0 to declare $1
6991 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
6992 AC_TRY_COMPILE([
6993 #include <stdlib.h>
6994 #include <stdarg.h>
6995 #include <stdio.h>
6996 #ifdef HAVE_LIBUTF8_H
6997 #include <libutf8.h>
6998 #endif],
6999         [$1 state],
7000         [cf_cv_$1=no],
7001         [AC_TRY_COMPILE([
7002 #include <stdlib.h>
7003 #include <stdarg.h>
7004 #include <stdio.h>
7005 #include <wchar.h>
7006 #ifdef HAVE_LIBUTF8_H
7007 #include <libutf8.h>
7008 #endif],
7009         [$1 value],
7010         [cf_cv_$1=yes],
7011         [cf_cv_$1=unknown])])])
7012
7013 if test "$cf_cv_$1" = yes ; then
7014         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
7015         NEED_WCHAR_H=1
7016 fi
7017
7018 ifelse([$2],,,[
7019 # if we do not find $1 in either place, use substitution to provide a fallback.
7020 if test "$cf_cv_$1" = unknown ; then
7021         $2=1
7022 fi
7023 ])
7024 ifelse($3,,,[
7025 # if we find $1 in either place, use substitution to provide a fallback.
7026 if test "$cf_cv_$1" != unknown ; then
7027         $3=1
7028 fi
7029 ])
7030 ])dnl
7031 dnl ---------------------------------------------------------------------------
7032 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
7033 dnl ---------------
7034 dnl Check for compiler-support for weak symbols.
7035 dnl This works with "recent" gcc.
7036 AC_DEFUN([CF_WEAK_SYMBOLS],[
7037 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
7038
7039 AC_TRY_COMPILE([
7040 #include <stdio.h>],
7041 [
7042 #if defined(__GNUC__)
7043 #  if defined __USE_ISOC99
7044 #    define _cat_pragma(exp)    _Pragma(#exp)
7045 #    define _weak_pragma(exp)   _cat_pragma(weak name)
7046 #  else
7047 #    define _weak_pragma(exp)
7048 #  endif
7049 #  define _declare(name)        __extension__ extern __typeof__(name) name
7050 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
7051 #endif
7052
7053 weak_symbol(fopen);
7054 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
7055 ])
7056 ])dnl
7057 dnl ---------------------------------------------------------------------------
7058 dnl CF_WITH_ABI_VERSION version: 3 updated: 2015/06/06 16:10:11
7059 dnl -------------------
7060 dnl Allow library's ABI to be overridden.  Generally this happens when a
7061 dnl packager has incremented the ABI past that used in the original package,
7062 dnl and wishes to keep doing this.
7063 dnl
7064 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
7065 dnl symbol.
7066 AC_DEFUN([CF_WITH_ABI_VERSION],[
7067 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
7068 AC_ARG_WITH(abi-version,
7069 [  --with-abi-version=XXX  override derived ABI version],[
7070         if test "x$cf_cv_abi_version" != "x$withval"
7071         then
7072                 AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
7073                 case $cf_cv_rel_version in
7074                 (5.*)
7075                         cf_cv_rel_version=$withval.0
7076                         ;;
7077                 (6.*)
7078                         cf_cv_rel_version=$withval.9    # FIXME: should be 10 as of 6.0 release
7079                         ;;
7080                 esac
7081         fi
7082         cf_cv_abi_version=$withval])
7083         CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
7084 ifelse($1,,,[
7085 $1_ABI=$cf_cv_abi_version
7086 ])
7087 ])dnl
7088 dnl ---------------------------------------------------------------------------
7089 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
7090 dnl --------------------
7091 dnl Command-line option to specify the Ada95 compiler.
7092 AC_DEFUN([CF_WITH_ADA_COMPILER],[
7093 AC_MSG_CHECKING(for ada-compiler)
7094 AC_ARG_WITH(ada-compiler,
7095         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
7096         [cf_ada_compiler=$withval],
7097         [cf_ada_compiler=gnatmake])
7098 AC_SUBST(cf_ada_compiler)
7099 AC_MSG_RESULT($cf_ada_compiler)
7100 ])dnl
7101 dnl ---------------------------------------------------------------------------
7102 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
7103 dnl -------------------
7104 dnl Command-line option to specify where Ada includes will install.
7105 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
7106 AC_MSG_CHECKING(for ada-include)
7107 CF_WITH_PATH(ada-include,
7108    [  --with-ada-include=DIR  Ada includes are in DIR],
7109    ADA_INCLUDE,
7110    PREFIX/share/ada/adainclude,
7111    [$]prefix/share/ada/adainclude)
7112 AC_SUBST(ADA_INCLUDE)
7113 AC_MSG_RESULT($ADA_INCLUDE)
7114 ])dnl
7115 dnl ---------------------------------------------------------------------------
7116 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
7117 dnl -------------------
7118 dnl Command-line option to specify where Ada objects will install.
7119 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
7120 AC_MSG_CHECKING(for ada-objects)
7121 CF_WITH_PATH(ada-objects,
7122    [  --with-ada-objects=DIR  Ada objects are in DIR],
7123    ADA_OBJECTS,
7124    PREFIX/lib/ada/adalib,
7125    [$]prefix/lib/ada/adalib)
7126 AC_SUBST(ADA_OBJECTS)
7127 AC_MSG_RESULT($ADA_OBJECTS)
7128 ])dnl
7129 dnl ---------------------------------------------------------------------------
7130 dnl CF_WITH_ADA_SHAREDLIB version: 4 updated: 2014/05/31 21:08:37
7131 dnl ---------------------
7132 dnl Command-line option to specify if an Ada95 shared-library should be built,
7133 dnl and optionally what its soname should be.
7134 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
7135 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
7136 AC_ARG_WITH(ada-sharedlib,
7137         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
7138         [with_ada_sharedlib=$withval],
7139         [with_ada_sharedlib=no])
7140 AC_MSG_RESULT($with_ada_sharedlib)
7141
7142 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
7143 MAKE_ADA_SHAREDLIB="#"
7144
7145 if test "x$with_ada_sharedlib" != xno
7146 then
7147         MAKE_ADA_SHAREDLIB=
7148         if test "x$with_ada_sharedlib" != xyes
7149         then
7150                 ADA_SHAREDLIB="$with_ada_sharedlib"
7151         fi
7152 fi
7153
7154 AC_SUBST(ADA_SHAREDLIB)
7155 AC_SUBST(MAKE_ADA_SHAREDLIB)
7156 ])dnl
7157 dnl ---------------------------------------------------------------------------
7158 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
7159 dnl ----------------
7160 dnl Configure-option for dbmalloc.  The optional parameter is used to override
7161 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
7162 AC_DEFUN([CF_WITH_DBMALLOC],[
7163 CF_NO_LEAKS_OPTION(dbmalloc,
7164         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
7165         [USE_DBMALLOC])
7166
7167 if test "$with_dbmalloc" = yes ; then
7168         AC_CHECK_HEADER(dbmalloc.h,
7169                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
7170 fi
7171 ])dnl
7172 dnl ---------------------------------------------------------------------------
7173 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
7174 dnl ---------------
7175 dnl Configure-option for dmalloc.  The optional parameter is used to override
7176 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
7177 AC_DEFUN([CF_WITH_DMALLOC],[
7178 CF_NO_LEAKS_OPTION(dmalloc,
7179         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
7180         [USE_DMALLOC])
7181
7182 if test "$with_dmalloc" = yes ; then
7183         AC_CHECK_HEADER(dmalloc.h,
7184                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
7185 fi
7186 ])dnl
7187 dnl ---------------------------------------------------------------------------
7188 dnl CF_WITH_EXPORT_SYMS version: 3 updated: 2014/12/20 19:16:08
7189 dnl -------------------
7190 dnl Use this with libtool to specify the list of symbols that may be exported.
7191 dnl The input file contains one symbol per line; comments work with "#".
7192 dnl
7193 dnl $1 = basename of the ".sym" file (default $PACKAGE)
7194 AC_DEFUN([CF_WITH_EXPORT_SYMS],
7195 [
7196 AC_MSG_CHECKING(if exported-symbols file should be used)
7197 AC_ARG_WITH(export-syms,
7198         [  --with-export-syms=XXX  limit exported symbols using libtool],
7199         [with_export_syms=$withval],
7200         [with_export_syms=no])
7201 if test "x$with_export_syms" = xyes
7202 then
7203         with_export_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).sym'
7204         AC_SUBST(PACKAGE)
7205 fi
7206 AC_MSG_RESULT($with_export_syms)
7207 if test "x$with_export_syms" != xno
7208 then
7209         EXPORT_SYMS="-export-symbols $with_export_syms"
7210         AC_SUBST(EXPORT_SYMS)
7211 fi
7212 ])dnl
7213 dnl ---------------------------------------------------------------------------
7214 dnl CF_WITH_GPM version: 9 updated: 2016/05/28 20:33:31
7215 dnl -----------
7216 dnl
7217 dnl The option parameter (if neither yes/no) is assumed to be the name of
7218 dnl the gpm library, e.g., for dynamic loading.
7219 AC_DEFUN([CF_WITH_GPM],
7220 [
7221 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
7222 AC_ARG_WITH(gpm,
7223         [  --with-gpm              use Alessandro Rubini's GPM library],
7224         [with_gpm=$withval],
7225         [with_gpm=maybe])
7226 AC_MSG_RESULT($with_gpm)
7227
7228 if test "$with_gpm" != no ; then
7229         AC_CHECK_HEADER(gpm.h,[
7230                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
7231                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
7232                         CF_VERBOSE(assuming we really have GPM library)
7233                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
7234                         with_gpm=yes
7235                 else
7236                         AC_CHECK_LIB(gpm,Gpm_Open,[:],[
7237                                 if test "$with_gpm" = maybe; then
7238                                         AC_MSG_WARN(Cannot link with GPM library)
7239                                         with_gpm=no
7240                                 else
7241                                         AC_MSG_ERROR(Cannot link with GPM library)
7242                                 fi
7243                         ])
7244                 fi
7245         ],[
7246                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
7247                 with_gpm=no
7248         ])
7249 fi
7250 ])
7251 dnl ---------------------------------------------------------------------------
7252 dnl CF_WITH_LIBTOOL version: 33 updated: 2015/10/17 19:03:33
7253 dnl ---------------
7254 dnl Provide a configure option to incorporate libtool.  Define several useful
7255 dnl symbols for the makefile rules.
7256 dnl
7257 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
7258 dnl macros from libtool.m4 which is in the aclocal directory of automake.
7259 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
7260 dnl But that still does not work properly since the macro is expanded outside
7261 dnl the CF_WITH_LIBTOOL macro:
7262 dnl
7263 dnl     #!/bin/sh
7264 dnl     ACLOCAL=`aclocal --print-ac-dir`
7265 dnl     if test -z "$ACLOCAL" ; then
7266 dnl             echo cannot find aclocal directory
7267 dnl             exit 1
7268 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
7269 dnl             echo cannot find libtool.m4 file
7270 dnl             exit 1
7271 dnl     fi
7272 dnl
7273 dnl     LOCAL=aclocal.m4
7274 dnl     ORIG=aclocal.m4.orig
7275 dnl
7276 dnl     trap "mv $ORIG $LOCAL" 0 1 2 5 15
7277 dnl     rm -f $ORIG
7278 dnl     mv $LOCAL $ORIG
7279 dnl
7280 dnl     # sed the LIBTOOL= assignment to omit the current directory?
7281 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
7282 dnl     cat $ORIG >>$LOCAL
7283 dnl
7284 dnl     autoconf-257 $*
7285 dnl
7286 AC_DEFUN([CF_WITH_LIBTOOL],
7287 [
7288 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
7289 ifdef([AC_PROG_LIBTOOL],,[
7290 LIBTOOL=
7291 ])
7292 # common library maintenance symbols that are convenient for libtool scripts:
7293 LIB_CREATE='${AR} -cr'
7294 LIB_OBJECT='${OBJECTS}'
7295 LIB_SUFFIX=.a
7296 LIB_PREP="$RANLIB"
7297
7298 # symbols used to prop libtool up to enable it to determine what it should be
7299 # doing:
7300 LIB_CLEAN=
7301 LIB_COMPILE=
7302 LIB_LINK='${CC}'
7303 LIB_INSTALL=
7304 LIB_UNINSTALL=
7305
7306 AC_MSG_CHECKING(if you want to build libraries with libtool)
7307 AC_ARG_WITH(libtool,
7308         [  --with-libtool          generate libraries with libtool],
7309         [with_libtool=$withval],
7310         [with_libtool=no])
7311 AC_MSG_RESULT($with_libtool)
7312 if test "$with_libtool" != "no"; then
7313 ifdef([AC_PROG_LIBTOOL],[
7314         # missing_content_AC_PROG_LIBTOOL{{
7315         AC_PROG_LIBTOOL
7316         # missing_content_AC_PROG_LIBTOOL}}
7317 ],[
7318         if test "$with_libtool" != "yes" ; then
7319                 CF_PATH_SYNTAX(with_libtool)
7320                 LIBTOOL=$with_libtool
7321         else
7322                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
7323                 CF_LIBTOOL_VERSION
7324                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
7325                 then
7326                         CF_FORGET_TOOL(LIBTOOL)
7327                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
7328                         CF_LIBTOOL_VERSION
7329                 fi
7330         fi
7331         if test -z "$LIBTOOL" ; then
7332                 AC_MSG_ERROR(Cannot find libtool)
7333         fi
7334 ])dnl
7335         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${DESTDIR}${libdir} ${LIBTOOL_VERSION} `cut -f1 ${top_srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
7336         LIB_OBJECT='${OBJECTS:.o=.lo}'
7337         LIB_SUFFIX=.la
7338         LIB_CLEAN='${LIBTOOL} --mode=clean'
7339         LIB_COMPILE='${LIBTOOL} --mode=compile'
7340         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
7341         LIB_INSTALL='${LIBTOOL} --mode=install'
7342         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
7343         LIB_PREP=:
7344
7345         CF_CHECK_LIBTOOL_VERSION
7346
7347         # special hack to add -no-undefined (which libtool should do for itself)
7348         LT_UNDEF=
7349         case "$cf_cv_system_name" in
7350         (cygwin*|msys*|mingw32*|os2*|uwin*|aix[[4-7]])
7351                 LT_UNDEF=-no-undefined
7352                 ;;
7353         esac
7354         AC_SUBST([LT_UNDEF])
7355
7356         # special hack to add --tag option for C++ compiler
7357         case $cf_cv_libtool_version in
7358         (1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*)
7359                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
7360                 LIBTOOL="$LIBTOOL --tag=CC"
7361                 ;;
7362         (*)
7363                 LIBTOOL_CXX="$LIBTOOL"
7364                 ;;
7365         esac
7366 else
7367         LIBTOOL=""
7368         LIBTOOL_CXX=""
7369 fi
7370
7371 test -z "$LIBTOOL" && ECHO_LT=
7372
7373 AC_SUBST(LIBTOOL)
7374 AC_SUBST(LIBTOOL_CXX)
7375 AC_SUBST(LIBTOOL_OPTS)
7376
7377 AC_SUBST(LIB_CREATE)
7378 AC_SUBST(LIB_OBJECT)
7379 AC_SUBST(LIB_SUFFIX)
7380 AC_SUBST(LIB_PREP)
7381
7382 AC_SUBST(LIB_CLEAN)
7383 AC_SUBST(LIB_COMPILE)
7384 AC_SUBST(LIB_LINK)
7385 AC_SUBST(LIB_INSTALL)
7386 AC_SUBST(LIB_UNINSTALL)
7387
7388 ])dnl
7389 dnl ---------------------------------------------------------------------------
7390 dnl CF_WITH_LIBTOOL_OPTS version: 4 updated: 2015/04/17 21:13:04
7391 dnl --------------------
7392 dnl Allow user to pass additional libtool options into the library creation
7393 dnl and link steps.  The main use for this is to do something like
7394 dnl     ./configure --with-libtool-opts=-static
7395 dnl to get the same behavior as automake-flavored
7396 dnl     ./configure --enable-static
7397 AC_DEFUN([CF_WITH_LIBTOOL_OPTS],[
7398 AC_MSG_CHECKING(for additional libtool options)
7399 AC_ARG_WITH(libtool-opts,
7400         [  --with-libtool-opts=XXX specify additional libtool options],
7401         [with_libtool_opts=$withval],
7402         [with_libtool_opts=no])
7403 AC_MSG_RESULT($with_libtool_opts)
7404
7405 case .$with_libtool_opts in
7406 (.yes|.no|.)
7407         ;;
7408 (*)
7409         LIBTOOL_OPTS="$LIBTOOL_OPTS $with_libtool_opts"
7410         ;;
7411 esac
7412
7413 AC_SUBST(LIBTOOL_OPTS)
7414 ])dnl
7415 dnl ---------------------------------------------------------------------------
7416 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
7417 dnl ------------------
7418 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
7419 dnl "lib" prefix, e.g., because it used the dll naming convention.
7420 dnl
7421 dnl $1 = variable to set
7422 AC_DEFUN([CF_WITH_LIB_PREFIX],
7423 [
7424 AC_MSG_CHECKING(if you want to have a library-prefix)
7425 AC_ARG_WITH(lib-prefix,
7426         [  --with-lib-prefix       override library-prefix],
7427         [with_lib_prefix=$withval],
7428         [with_lib_prefix=auto])
7429 AC_MSG_RESULT($with_lib_prefix)
7430
7431 if test $with_lib_prefix = auto
7432 then
7433         CF_LIB_PREFIX($1)
7434 elif test $with_lib_prefix = no
7435 then
7436         LIB_PREFIX=
7437 else
7438         LIB_PREFIX=$with_lib_prefix
7439 fi
7440 ])dnl
7441 dnl ---------------------------------------------------------------------------
7442 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
7443 dnl ------------
7444 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
7445 dnl defaulting to yes/no.
7446 dnl
7447 dnl $1 = option name
7448 dnl $2 = help-text
7449 dnl $3 = environment variable to set
7450 dnl $4 = default value, shown in the help-message, must be a constant
7451 dnl $5 = default value, if it's an expression & cannot be in the help-message
7452 dnl
7453 AC_DEFUN([CF_WITH_PATH],
7454 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
7455 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
7456 if ifelse([$5],,true,[test -n "$5"]) ; then
7457 CF_PATH_SYNTAX(withval)
7458 fi
7459 eval $3="$withval"
7460 AC_SUBST($3)dnl
7461 ])dnl
7462 dnl ---------------------------------------------------------------------------
7463 dnl CF_WITH_PATHLIST version: 10 updated: 2015/04/17 21:13:04
7464 dnl ----------------
7465 dnl Process an option specifying a list of colon-separated paths.
7466 dnl
7467 dnl $1 = option name
7468 dnl $2 = help-text
7469 dnl $3 = environment variable to set
7470 dnl $4 = default value, shown in the help-message, must be a constant
7471 dnl $5 = default value, if it's an expression & cannot be in the help-message
7472 dnl $6 = flag to tell if we want to define or substitute
7473 dnl
7474 AC_DEFUN([CF_WITH_PATHLIST],[
7475 AC_REQUIRE([CF_PATHSEP])
7476 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
7477 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
7478
7479 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
7480 cf_dst_path=
7481 for cf_src_path in $withval
7482 do
7483   CF_PATH_SYNTAX(cf_src_path)
7484   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
7485   cf_dst_path="${cf_dst_path}${cf_src_path}"
7486 done
7487 IFS="$ac_save_ifs"
7488
7489 ifelse($6,define,[
7490 # Strip single quotes from the value, e.g., when it was supplied as a literal
7491 # for $4 or $5.
7492 case $cf_dst_path in
7493 (\'*)
7494   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
7495   ;;
7496 esac
7497 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
7498 ])
7499
7500 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
7501 # so we have to check/work around.  We do prefer the result of "eval"...
7502 eval cf_dst_eval="$cf_dst_path"
7503 case "x$cf_dst_eval" in
7504 (xNONE*)
7505         $3=$cf_dst_path
7506         ;;
7507 (*)
7508         $3="$cf_dst_eval"
7509         ;;
7510 esac
7511 AC_SUBST($3)dnl
7512
7513 ])dnl
7514 dnl ---------------------------------------------------------------------------
7515 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 10 updated: 2015/08/22 17:10:56
7516 dnl -------------------------
7517 dnl Allow the choice of the pkg-config library directory to be overridden.
7518 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
7519
7520 case $PKG_CONFIG in
7521 (no|none|yes)
7522         AC_MSG_CHECKING(for pkg-config library directory)
7523         ;;
7524 (*)
7525         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
7526         ;;
7527 esac
7528
7529 PKG_CONFIG_LIBDIR=no
7530 AC_ARG_WITH(pkg-config-libdir,
7531         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
7532         [PKG_CONFIG_LIBDIR=$withval],
7533         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
7534
7535 case x$PKG_CONFIG_LIBDIR in
7536 (x/*)
7537         ;;
7538 (xyes)
7539         # Look for the library directory using the same prefix as the executable
7540         if test "x$PKG_CONFIG" = xnone
7541         then
7542                 cf_path=$prefix
7543         else
7544                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
7545         fi
7546
7547         # If you don't like using the default architecture, you have to specify the
7548         # intended library directory and corresponding compiler/linker options.
7549         #
7550         # This case allows for Debian's 2014-flavor of multiarch, along with the
7551         # most common variations before that point.  Some other variants spell the
7552         # directory differently, e.g., "pkg-config", and put it in unusual places.
7553         # pkg-config has always been poorly standardized, which is ironic...
7554         case x`(arch) 2>/dev/null` in
7555         (*64)
7556                 cf_search_path="\
7557                         $cf_path/lib/*64-linux-gnu \
7558                         $cf_path/share \
7559                         $cf_path/lib64 \
7560                         $cf_path/lib32 \
7561                         $cf_path/lib"
7562                 ;;
7563         (*)
7564                 cf_search_path="\
7565                         $cf_path/lib/*-linux-gnu \
7566                         $cf_path/share \
7567                         $cf_path/lib32 \
7568                         $cf_path/lib \
7569                         $cf_path/libdata"
7570                 ;;
7571         esac
7572
7573         CF_VERBOSE(list...)
7574         for cf_config in $cf_search_path
7575         do
7576                 CF_VERBOSE(checking $cf_config/pkgconfig)
7577                 if test -d $cf_config/pkgconfig
7578                 then
7579                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
7580                         AC_MSG_CHECKING(done)
7581                         break
7582                 fi
7583         done
7584         ;;
7585 (*)
7586         ;;
7587 esac
7588
7589 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
7590         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
7591 fi
7592
7593 AC_SUBST(PKG_CONFIG_LIBDIR)
7594 ])dnl
7595 dnl ---------------------------------------------------------------------------
7596 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
7597 dnl ---------------
7598 dnl Check for POSIX thread library.
7599 AC_DEFUN([CF_WITH_PTHREAD],
7600 [
7601 AC_MSG_CHECKING(if you want to link with the pthread library)
7602 AC_ARG_WITH(pthread,
7603         [  --with-pthread          use POSIX thread library],
7604         [with_pthread=$withval],
7605         [with_pthread=no])
7606 AC_MSG_RESULT($with_pthread)
7607
7608 if test "$with_pthread" != no ; then
7609         AC_CHECK_HEADER(pthread.h,[
7610         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
7611
7612         for cf_lib_pthread in pthread c_r
7613         do
7614             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
7615             cf_save_LIBS="$LIBS"
7616             CF_ADD_LIB($cf_lib_pthread)
7617             AC_TRY_LINK([
7618 #include <pthread.h>
7619 ],[
7620                 int rc = pthread_create(0,0,0,0);
7621                 int r2 = pthread_mutexattr_settype(0, 0);
7622 ],[with_pthread=yes],[with_pthread=no])
7623             LIBS="$cf_save_LIBS"
7624             AC_MSG_RESULT($with_pthread)
7625             test "$with_pthread" = yes && break
7626         done
7627
7628         if test "$with_pthread" = yes ; then
7629             CF_ADD_LIB($cf_lib_pthread)
7630             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
7631         else
7632             AC_MSG_ERROR(Cannot link with pthread library)
7633         fi
7634         ])
7635 fi
7636 ])
7637 dnl ---------------------------------------------------------------------------
7638 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
7639 dnl -------------------
7640 dnl Allow library's release-version to be overridden.  Generally this happens when a
7641 dnl packager has incremented the release-version past that used in the original package,
7642 dnl and wishes to keep doing this.
7643 dnl
7644 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
7645 dnl and {package}_MINOR symbols
7646 dnl symbol.
7647 AC_DEFUN([CF_WITH_REL_VERSION],[
7648 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
7649 AC_ARG_WITH(rel-version,
7650 [  --with-rel-version=XXX  override derived release version],
7651 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
7652  cf_cv_rel_version=$withval])
7653 ifelse($1,,[
7654  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
7655 ],[
7656  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
7657  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
7658  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
7659  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
7660 ])
7661 ])dnl
7662 dnl ---------------------------------------------------------------------------
7663 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
7664 dnl ----------------
7665 dnl If we can compile with sysmouse, make it available unless it is not wanted.
7666 AC_DEFUN([CF_WITH_SYSMOUSE],[
7667 # not everyone has "test -c"
7668 if test -c /dev/sysmouse 2>/dev/null ; then
7669 AC_MSG_CHECKING(if you want to use sysmouse)
7670 AC_ARG_WITH(sysmouse,
7671         [  --with-sysmouse         use sysmouse (FreeBSD console)],
7672         [cf_with_sysmouse=$withval],
7673         [cf_with_sysmouse=maybe])
7674         if test "$cf_with_sysmouse" != no ; then
7675         AC_TRY_COMPILE([
7676 #include <osreldate.h>
7677 #if (__FreeBSD_version >= 400017)
7678 #include <sys/consio.h>
7679 #include <sys/fbio.h>
7680 #else
7681 #include <machine/console.h>
7682 #endif
7683 ],[
7684         struct mouse_info the_mouse;
7685         ioctl(0, CONS_MOUSECTL, &the_mouse);
7686 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
7687         fi
7688 AC_MSG_RESULT($cf_with_sysmouse)
7689 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
7690 fi
7691 ])dnl
7692 dnl ---------------------------------------------------------------------------
7693 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
7694 dnl ---------------
7695 dnl For testing, override the derived host system-type which is used to decide
7696 dnl things such as the linker commands used to build shared libraries.  This is
7697 dnl normally chosen automatically based on the type of system which you are
7698 dnl building on.  We use it for testing the configure script.
7699 dnl
7700 dnl This is different from the --host option: it is used only for testing parts
7701 dnl of the configure script which would not be reachable with --host since that
7702 dnl relies on the build environment being real, rather than mocked up.
7703 AC_DEFUN([CF_WITH_SYSTYPE],[
7704 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
7705 AC_ARG_WITH(system-type,
7706         [  --with-system-type=XXX  test: override derived host system-type],
7707 [AC_MSG_WARN(overriding system type to $withval)
7708         cf_cv_system_name=$withval
7709         host_os=$withval
7710 ])
7711 ])dnl
7712 dnl ---------------------------------------------------------------------------
7713 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
7714 dnl ----------------
7715 AC_DEFUN([CF_WITH_VALGRIND],[
7716 CF_NO_LEAKS_OPTION(valgrind,
7717         [  --with-valgrind         test: use valgrind],
7718         [USE_VALGRIND])
7719 ])dnl
7720 dnl ---------------------------------------------------------------------------
7721 dnl CF_WITH_VERSIONED_SYMS version: 7 updated: 2015/10/24 20:50:26
7722 dnl ----------------------
7723 dnl Use this when building shared library with ELF, to markup symbols with the
7724 dnl version identifier from the given input file.  Generally that identifier is
7725 dnl the same as the SONAME at which the symbol was first introduced.
7726 dnl
7727 dnl $1 = basename of the ".map" file (default $PACKAGE)
7728 AC_DEFUN([CF_WITH_VERSIONED_SYMS],
7729 [
7730 AC_MSG_CHECKING(if versioned-symbols file should be used)
7731 AC_ARG_WITH(versioned-syms,
7732         [  --with-versioned-syms=X markup versioned symbols using ld],
7733         [with_versioned_syms=$withval],
7734         [with_versioned_syms=no])
7735 if test "x$with_versioned_syms" = xyes
7736 then
7737         with_versioned_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).map'
7738         AC_SUBST(PACKAGE)
7739 fi
7740 AC_MSG_RESULT($with_versioned_syms)
7741
7742 RESULTING_SYMS=
7743 VERSIONED_SYMS=
7744 WILDCARD_SYMS=
7745
7746 if test "x$with_versioned_syms" != xno
7747 then
7748         RESULTING_SYMS=$with_versioned_syms
7749         case "x$MK_SHARED_LIB" in
7750         (*-Wl,*)
7751                 VERSIONED_SYMS="-Wl,--version-script,\${RESULTING_SYMS}"
7752                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-Wl,%\\[$]{VERSIONED_SYMS} -Wl,%"`
7753                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7754                 ;;
7755         (*-dy\ *)
7756                 VERSIONED_SYMS="-Wl,-M,\${RESULTING_SYMS}"
7757                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-dy%\\[$]{VERSIONED_SYMS} -dy%"`
7758                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7759                 ;;
7760         (*)
7761                 AC_MSG_WARN(this system does not support versioned-symbols)
7762                 ;;
7763         esac
7764
7765         # Linux ld can selectively override scope, e.g., of symbols beginning with
7766         # "_" by first declaring some as global, and then using a wildcard to
7767         # declare the others as local.  Some other loaders cannot do this.  Check
7768         # by constructing a (very) simple shared library and inspecting its
7769         # symbols.
7770         if test "x$VERSIONED_SYMS" != "x"
7771         then
7772                 AC_MSG_CHECKING(if wildcards can be used to selectively omit symbols)
7773                 WILDCARD_SYMS=no
7774
7775                 # make sources
7776                 rm -f conftest.*
7777
7778                 cat >conftest.ver <<EOF
7779 module_1.0 {
7780 global:
7781         globalf1;
7782 local:
7783         localf1;
7784 };
7785 module_2.0 {
7786 global:
7787         globalf2;
7788 local:
7789         localf2;
7790         _*;
7791 } module_1.0;
7792 submodule_1.0 {
7793 global:
7794         subglobalf1;
7795         _ismissing;
7796 local:
7797         sublocalf1;
7798 };
7799 submodule_2.0 {
7800 global:
7801         subglobalf2;
7802 local:
7803         sublocalf2;
7804         _*;
7805 } submodule_1.0;
7806 EOF
7807                 cat >conftest.$ac_ext <<EOF
7808 #line __oline__ "configure"
7809 int     _ismissing(void) { return 1; }
7810 int     _localf1(void) { return 1; }
7811 int     _localf2(void) { return 2; }
7812 int     globalf1(void) { return 1; }
7813 int     globalf2(void) { return 2; }
7814 int     _sublocalf1(void) { return 1; }
7815 int     _sublocalf2(void) { return 2; }
7816 int     subglobalf1(void) { return 1; }
7817 int     subglobalf2(void) { return 2; }
7818 EOF
7819                 cat >conftest.mk <<EOF
7820 CC=${CC}
7821 CFLAGS=${CFLAGS}
7822 CPPFLAGS=${CPPFLAGS}
7823 LDFLAGS=${LDFLAGS}
7824 LIBS=${LIBS}
7825 VERSIONED_SYMS=${VERSIONED_SYMS}
7826 RESULTING_SYMS=conftest.ver
7827 MK_SHARED_LIB=${MK_SHARED_LIB}
7828 conftest.so: conftest.$ac_cv_objext
7829                 \$(MK_SHARED_LIB) conftest.$ac_cv_objext
7830 EOF
7831
7832                 # compile source, make library
7833                 if make -f conftest.mk 2>&AC_FD_CC >/dev/null
7834                 then
7835                         # test for missing symbol in either Data or Text section
7836                         cf_missing=`nm -P conftest.so 2>&AC_FD_CC |fgrep _ismissing | egrep '[[         ]][[DT]][[      ]]'`
7837                         test -n "$cf_missing" && WILDCARD_SYMS=yes
7838                 fi
7839                 AC_MSG_RESULT($WILDCARD_SYMS)
7840                 rm -f conftest.*
7841         fi
7842 fi
7843 AC_SUBST(RESULTING_SYMS)
7844 AC_SUBST(VERSIONED_SYMS)
7845 AC_SUBST(WILDCARD_SYMS)
7846 ])dnl
7847 dnl ---------------------------------------------------------------------------
7848 dnl CF_XOPEN_SOURCE version: 52 updated: 2016/08/27 12:21:42
7849 dnl ---------------
7850 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
7851 dnl or adapt to the vendor's definitions to get equivalent functionality,
7852 dnl without losing the common non-POSIX features.
7853 dnl
7854 dnl Parameters:
7855 dnl     $1 is the nominal value for _XOPEN_SOURCE
7856 dnl     $2 is the nominal value for _POSIX_C_SOURCE
7857 AC_DEFUN([CF_XOPEN_SOURCE],[
7858 AC_REQUIRE([AC_CANONICAL_HOST])
7859
7860 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
7861 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
7862 cf_xopen_source=
7863
7864 case $host_os in
7865 (aix[[4-7]]*)
7866         cf_xopen_source="-D_ALL_SOURCE"
7867         ;;
7868 (msys)
7869         cf_XOPEN_SOURCE=600
7870         ;;
7871 (darwin[[0-8]].*)
7872         cf_xopen_source="-D_APPLE_C_SOURCE"
7873         ;;
7874 (darwin*)
7875         cf_xopen_source="-D_DARWIN_C_SOURCE"
7876         cf_XOPEN_SOURCE=
7877         ;;
7878 (freebsd*|dragonfly*)
7879         # 5.x headers associate
7880         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
7881         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
7882         cf_POSIX_C_SOURCE=200112L
7883         cf_XOPEN_SOURCE=600
7884         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
7885         ;;
7886 (hpux11*)
7887         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
7888         ;;
7889 (hpux*)
7890         cf_xopen_source="-D_HPUX_SOURCE"
7891         ;;
7892 (irix[[56]].*)
7893         cf_xopen_source="-D_SGI_SOURCE"
7894         cf_XOPEN_SOURCE=
7895         ;;
7896 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
7897         CF_GNU_SOURCE
7898         ;;
7899 (minix*)
7900         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
7901         ;;
7902 (mirbsd*)
7903         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
7904         cf_XOPEN_SOURCE=
7905         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7906         ;;
7907 (netbsd*)
7908         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
7909         ;;
7910 (openbsd[[4-9]]*)
7911         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
7912         cf_xopen_source="-D_BSD_SOURCE"
7913         cf_XOPEN_SOURCE=600
7914         ;;
7915 (openbsd*)
7916         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
7917         ;;
7918 (osf[[45]]*)
7919         cf_xopen_source="-D_OSF_SOURCE"
7920         ;;
7921 (nto-qnx*)
7922         cf_xopen_source="-D_QNX_SOURCE"
7923         ;;
7924 (sco*)
7925         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
7926         ;;
7927 (solaris2.*)
7928         cf_xopen_source="-D__EXTENSIONS__"
7929         cf_cv_xopen_source=broken
7930         ;;
7931 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
7932         cf_XOPEN_SOURCE=
7933         cf_POSIX_C_SOURCE=
7934         ;;
7935 (*)
7936         CF_TRY_XOPEN_SOURCE
7937         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7938         ;;
7939 esac
7940
7941 if test -n "$cf_xopen_source" ; then
7942         CF_ADD_CFLAGS($cf_xopen_source,true)
7943 fi
7944
7945 dnl In anything but the default case, we may have system-specific setting
7946 dnl which is still not guaranteed to provide all of the entrypoints that
7947 dnl _XOPEN_SOURCE would yield.
7948 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
7949         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
7950         AC_TRY_COMPILE([#include <stdlib.h>],[
7951 #ifndef _XOPEN_SOURCE
7952 make an error
7953 #endif],
7954         [cf_XOPEN_SOURCE_set=yes],
7955         [cf_XOPEN_SOURCE_set=no])
7956         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
7957         if test $cf_XOPEN_SOURCE_set = yes
7958         then
7959                 AC_TRY_COMPILE([#include <stdlib.h>],[
7960 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
7961 make an error
7962 #endif],
7963                 [cf_XOPEN_SOURCE_set_ok=yes],
7964                 [cf_XOPEN_SOURCE_set_ok=no])
7965                 if test $cf_XOPEN_SOURCE_set_ok = no
7966                 then
7967                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
7968                 fi
7969         else
7970                 CF_TRY_XOPEN_SOURCE
7971         fi
7972 fi
7973 ])