aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2018,2019 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.862 2019/03/30 21:53:01 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See https://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54         [AC_TRY_LINK([#include <langinfo.h>],
  55         [char* cs = nl_langinfo(CODESET);],
  56         am_cv_langinfo_codeset=yes,
  57         am_cv_langinfo_codeset=no)
  58         ])
  59         if test $am_cv_langinfo_codeset = yes; then
  60                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62         fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
  66 dnl ---------------
  67 dnl Provide configure-script defaults for different ncurses ABIs.
  68 AC_DEFUN([CF_ABI_DEFAULTS],[
  69 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  70 case x$cf_cv_abi_version in
  71 (x[[6789]])
  72         cf_dft_ext_colors=yes
  73         cf_dft_ext_const=yes
  74         cf_dft_ext_mouse=yes
  75         cf_dft_ext_putwin=yes
  76         cf_dft_ext_spfuncs=yes
  77         cf_dft_filter_syms=yes
  78         cf_dft_chtype=uint32_t
  79         cf_dft_mmask_t=uint32_t
  80         cf_dft_interop=yes
  81         cf_dft_tparm_arg=intptr_t
  82         cf_dft_with_lp64=yes
  83         ;;
  84 (*)
  85         cf_dft_ext_colors=no
  86         cf_dft_ext_const=no
  87         cf_dft_ext_mouse=no
  88         cf_dft_ext_putwin=no
  89         cf_dft_ext_spfuncs=no
  90         cf_dft_filter_syms=no
  91         cf_dft_chtype=auto
  92         cf_dft_mmask_t=auto
  93         cf_dft_interop=no
  94         cf_dft_tparm_arg=long
  95         cf_dft_with_lp64=no
  96         ;;
  97 esac
  98 ])dnl
  99 dnl ---------------------------------------------------------------------------
 100 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 101 dnl ------------------
 102 dnl Conditionally generate script according to whether we're using a given autoconf.
 103 dnl
 104 dnl $1 = version to compare against
 105 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 106 dnl $3 = code to use if AC_ACVERSION is older than $1.
 107 define([CF_ACVERSION_CHECK],
 108 [
 109 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 110 ifdef([m4_version_compare],
 111 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 112 [CF_ACVERSION_COMPARE(
 113 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 114 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 115 dnl ---------------------------------------------------------------------------
 116 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 117 dnl --------------------
 118 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 119 dnl                      MAJOR2, MINOR2, TERNARY2,
 120 dnl                      PRINTABLE2, not FOUND, FOUND)
 121 define([CF_ACVERSION_COMPARE],
 122 [ifelse(builtin([eval], [$2 < $5]), 1,
 123 [ifelse([$8], , ,[$8])],
 124 [ifelse([$9], , ,[$9])])])dnl
 125 dnl ---------------------------------------------------------------------------
 126 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 127 dnl -------------------
 128 dnl Construct the list of include-options for the C programs in the Ada95
 129 dnl binding.
 130 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 131 [
 132 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 133 if test "$srcdir" != "."; then
 134         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 135 fi
 136 if test "$GCC" != yes; then
 137         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 138 elif test "$includedir" != "/usr/include"; then
 139         if test "$includedir" = '${prefix}/include' ; then
 140                 if test x$prefix != x/usr ; then
 141                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 142                 fi
 143         else
 144                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 145         fi
 146 fi
 147 AC_SUBST(ACPPFLAGS)
 148 ])dnl
 149 dnl ---------------------------------------------------------------------------
 150 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 151 dnl ---------------
 152 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 153 AC_DEFUN([CF_ADD_ADAFLAGS],[
 154         ADAFLAGS="$ADAFLAGS $1"
 155         AC_SUBST(ADAFLAGS)
 156 ])dnl
 157 dnl ---------------------------------------------------------------------------
 158 dnl CF_ADD_CFLAGS version: 13 updated: 2017/02/25 18:57:40
 159 dnl -------------
 160 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 161 dnl The second parameter if given makes this macro verbose.
 162 dnl
 163 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 164 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 165 dnl confused by the quotes (which require backslashes to keep them usable).
 166 AC_DEFUN([CF_ADD_CFLAGS],
 167 [
 168 cf_fix_cppflags=no
 169 cf_new_cflags=
 170 cf_new_cppflags=
 171 cf_new_extra_cppflags=
 172
 173 for cf_add_cflags in $1
 174 do
 175 case $cf_fix_cppflags in
 176 (no)
 177         case $cf_add_cflags in
 178         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 179                 case $cf_add_cflags in
 180                 (-D*)
 181                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 182
 183                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 184                                 && test -z "${cf_tst_cflags}" \
 185                                 && cf_fix_cppflags=yes
 186
 187                         if test $cf_fix_cppflags = yes ; then
 188                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 189                                 continue
 190                         elif test "${cf_tst_cflags}" = "\"'" ; then
 191                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 192                                 continue
 193                         fi
 194                         ;;
 195                 esac
 196                 case "$CPPFLAGS" in
 197                 (*$cf_add_cflags)
 198                         ;;
 199                 (*)
 200                         case $cf_add_cflags in
 201                         (-D*)
 202                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 203                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 204                                 ;;
 205                         esac
 206                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 207                         ;;
 208                 esac
 209                 ;;
 210         (*)
 211                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 212                 ;;
 213         esac
 214         ;;
 215 (yes)
 216         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 217
 218         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 219
 220         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 221                 && test -z "${cf_tst_cflags}" \
 222                 && cf_fix_cppflags=no
 223         ;;
 224 esac
 225 done
 226
 227 if test -n "$cf_new_cflags" ; then
 228         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 229         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 230 fi
 231
 232 if test -n "$cf_new_cppflags" ; then
 233         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 234         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 235 fi
 236
 237 if test -n "$cf_new_extra_cppflags" ; then
 238         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 239         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 240 fi
 241
 242 AC_SUBST(EXTRA_CPPFLAGS)
 243
 244 ])dnl
 245 dnl ---------------------------------------------------------------------------
 246 dnl CF_ADD_INCDIR version: 15 updated: 2018/06/20 20:23:13
 247 dnl -------------
 248 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 249 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 250 dnl but old versions (and some misinstalled ones) need that.  To make things
 251 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 252 dnl the include-path).
 253 AC_DEFUN([CF_ADD_INCDIR],
 254 [
 255 if test -n "$1" ; then
 256   for cf_add_incdir in $1
 257   do
 258         while test $cf_add_incdir != /usr/include
 259         do
 260           if test -d $cf_add_incdir
 261           then
 262                 cf_have_incdir=no
 263                 if test -n "$CFLAGS$CPPFLAGS" ; then
 264                   # a loop is needed to ensure we can add subdirs of existing dirs
 265                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 266                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 267                           cf_have_incdir=yes; break
 268                         fi
 269                   done
 270                 fi
 271
 272                 if test "$cf_have_incdir" = no ; then
 273                   if test "$cf_add_incdir" = /usr/local/include ; then
 274                         if test "$GCC" = yes
 275                         then
 276                           cf_save_CPPFLAGS=$CPPFLAGS
 277                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 278                           AC_TRY_COMPILE([#include <stdio.h>],
 279                                   [printf("Hello")],
 280                                   [],
 281                                   [cf_have_incdir=yes])
 282                           CPPFLAGS=$cf_save_CPPFLAGS
 283                         fi
 284                   fi
 285                 fi
 286
 287                 if test "$cf_have_incdir" = no ; then
 288                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 289                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 290
 291                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 292                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 293                   cf_add_incdir="$cf_top_incdir"
 294                 else
 295                   break
 296                 fi
 297           else
 298                 break
 299           fi
 300         done
 301   done
 302 fi
 303 ])dnl
 304 dnl ---------------------------------------------------------------------------
 305 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 306 dnl ----------
 307 dnl Add a library, used to enforce consistency.
 308 dnl
 309 dnl $1 = library to add, without the "-l"
 310 dnl $2 = variable to update (default $LIBS)
 311 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 312 dnl ---------------------------------------------------------------------------
 313 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 314 dnl -------------
 315 dnl     Adds to the library-path
 316 dnl
 317 dnl     Some machines have trouble with multiple -L options.
 318 dnl
 319 dnl $1 is the (list of) directory(s) to add
 320 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 321 dnl
 322 AC_DEFUN([CF_ADD_LIBDIR],
 323 [
 324 if test -n "$1" ; then
 325         for cf_add_libdir in $1
 326         do
 327                 if test $cf_add_libdir = /usr/lib ; then
 328                         :
 329                 elif test -d $cf_add_libdir
 330                 then
 331                         cf_have_libdir=no
 332                         if test -n "$LDFLAGS$LIBS" ; then
 333                                 # a loop is needed to ensure we can add subdirs of existing dirs
 334                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 335                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 336                                                 cf_have_libdir=yes; break
 337                                         fi
 338                                 done
 339                         fi
 340                         if test "$cf_have_libdir" = no ; then
 341                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 342                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 343                         fi
 344                 fi
 345         done
 346 fi
 347 ])dnl
 348 dnl ---------------------------------------------------------------------------
 349 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 350 dnl -----------
 351 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 352 dnl prepended to an existing list, since their dependencies are assumed to
 353 dnl already exist in the list.
 354 dnl
 355 dnl $1 = libraries to add, with the "-l", etc.
 356 dnl $2 = variable to update (default $LIBS)
 357 AC_DEFUN([CF_ADD_LIBS],[
 358 cf_add_libs="$1"
 359 # Filter out duplicates - this happens with badly-designed ".pc" files...
 360 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 361 do
 362         for cf_add_2lib in $cf_add_libs
 363         do
 364                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 365                 then
 366                         cf_add_1lib=
 367                         break
 368                 fi
 369         done
 370         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 371 done
 372 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 373 ])dnl
 374 dnl ---------------------------------------------------------------------------
 375 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 376 dnl ------------------
 377 dnl Append to a search-list for a nonstandard header/lib-file
 378 dnl     $1 = the variable to return as result
 379 dnl     $2 = the package name
 380 dnl     $3 = the subdirectory, e.g., bin, include or lib
 381 dnl $4 = the directory under which we will test for subdirectories
 382 dnl $5 = a directory that we do not want $4 to match
 383 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 384 [
 385 test "x$4" != "x$5" && \
 386 test -d "$4" && \
 387 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 388         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 389         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 390         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 391         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 392         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 393         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 394 }
 395 ])dnl
 396 dnl ---------------------------------------------------------------------------
 397 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 398 dnl --------------
 399 dnl use this macro for appending text without introducing an extra blank at
 400 dnl the beginning
 401 define([CF_APPEND_TEXT],
 402 [
 403         test -n "[$]$1" && $1="[$]$1 "
 404         $1="[$]{$1}$2"
 405 ])dnl
 406 dnl ---------------------------------------------------------------------------
 407 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 408 dnl --------------
 409 dnl Allow user to disable a normally-on option.
 410 AC_DEFUN([CF_ARG_DISABLE],
 411 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 412 dnl ---------------------------------------------------------------------------
 413 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 414 dnl -------------
 415 dnl Allow user to enable a normally-off option.
 416 AC_DEFUN([CF_ARG_ENABLE],
 417 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 418 dnl ---------------------------------------------------------------------------
 419 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 420 dnl -------------
 421 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 422 dnl values.
 423 dnl
 424 dnl Parameters:
 425 dnl $1 = option name
 426 dnl $2 = help-string
 427 dnl $3 = action to perform if option is not default
 428 dnl $4 = action if perform if option is default
 429 dnl $5 = default option value (either 'yes' or 'no')
 430 AC_DEFUN([CF_ARG_OPTION],
 431 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 432         if test "$enableval" != "$5" ; then
 433 ifelse([$3],,[    :]dnl
 434 ,[    $3]) ifelse([$4],,,[
 435         else
 436                 $4])
 437         fi],[enableval=$5 ifelse([$4],,,[
 438         $4
 439 ])dnl
 440 ])])dnl
 441 dnl ---------------------------------------------------------------------------
 442 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
 443 dnl -----------
 444 dnl Check for suitable "ar" (archiver) options for updating an archive.
 445 dnl
 446 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 447 dnl as well as a workaround for breakage of make's archive rules by the GNU
 448 dnl binutils "ar" program.
 449 AC_DEFUN([CF_AR_FLAGS],[
 450 AC_REQUIRE([CF_PROG_AR])
 451
 452 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 453         cf_cv_ar_flags=unknown
 454         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 455         do
 456
 457                 # check if $ARFLAGS already contains this choice
 458                 if test "x$ARFLAGS" != "x" ; then
 459                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 460                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 461                                 cf_cv_ar_flags=
 462                                 break
 463                         fi
 464                 fi
 465
 466                 rm -f conftest.$ac_cv_objext
 467                 rm -f conftest.a
 468
 469                 cat >conftest.$ac_ext <<EOF
 470 #line __oline__ "configure"
 471 int     testdata[[3]] = { 123, 456, 789 };
 472 EOF
 473                 if AC_TRY_EVAL(ac_compile) ; then
 474                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 475                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 476                         if test -f conftest.a ; then
 477                                 cf_cv_ar_flags=$cf_ar_flags
 478                                 break
 479                         fi
 480                 else
 481                         CF_VERBOSE(cannot compile test-program)
 482                         break
 483                 fi
 484         done
 485         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 486 ])
 487
 488 if test -n "$ARFLAGS" ; then
 489         if test -n "$cf_cv_ar_flags" ; then
 490                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 491         fi
 492 else
 493         ARFLAGS=$cf_cv_ar_flags
 494 fi
 495
 496 AC_SUBST(ARFLAGS)
 497 ])
 498 dnl ---------------------------------------------------------------------------
 499 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 500 dnl -----------------
 501 dnl Check if awk can handle big strings using printf.  Some older versions of
 502 dnl awk choke on large strings passed via "%s".
 503 dnl
 504 dnl $1 = desired string size
 505 dnl $2 = variable to set with result
 506 AC_DEFUN([CF_AWK_BIG_PRINTF],
 507 [
 508         case x$AWK in
 509         (x)
 510                 eval $2=no
 511                 ;;
 512         (*)
 513                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 514                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 515                         eval $2=yes
 516                 else
 517                         eval $2=no
 518                 fi
 519                 ;;
 520         esac
 521 ])dnl
 522 dnl ---------------------------------------------------------------------------
 523 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 524 dnl ------------
 525 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 526 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 527 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 528 dnl
 529 dnl Treat the configuration-variable specially here, since we're directly
 530 dnl substituting its value (i.e., 1/0).
 531 dnl
 532 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 533 AC_DEFUN([CF_BOOL_DECL],
 534 [
 535 AC_MSG_CHECKING(if we should include stdbool.h)
 536
 537 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 538         AC_TRY_COMPILE([],[bool foo = false],
 539                 [cf_cv_header_stdbool_h=0],
 540                 [AC_TRY_COMPILE([
 541 #ifndef __BEOS__
 542 #include <stdbool.h>
 543 #endif
 544 ],[bool foo = false],
 545                         [cf_cv_header_stdbool_h=1],
 546                         [cf_cv_header_stdbool_h=0])])])
 547
 548 if test "$cf_cv_header_stdbool_h" = 1
 549 then    AC_MSG_RESULT(yes)
 550 else    AC_MSG_RESULT(no)
 551 fi
 552
 553 AC_MSG_CHECKING([for builtin bool type])
 554
 555 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 556         AC_TRY_COMPILE([
 557 #include <stdio.h>
 558 #include <sys/types.h>
 559 ],[bool x = false],
 560                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 561                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 562         ])
 563
 564 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 565 then    AC_MSG_RESULT(yes)
 566 else    AC_MSG_RESULT(no)
 567 fi
 568 ])dnl
 569 dnl ---------------------------------------------------------------------------
 570 dnl CF_BOOL_SIZE version: 15 updated: 2017/01/21 11:06:25
 571 dnl ------------
 572 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 573 dnl Don't bother looking for bool.h, since it's been deprecated.
 574 dnl
 575 dnl If the current compiler is C rather than C++, we get the bool definition
 576 dnl from <stdbool.h>.
 577 AC_DEFUN([CF_BOOL_SIZE],
 578 [
 579 AC_MSG_CHECKING([for size of bool])
 580 AC_CACHE_VAL(cf_cv_type_of_bool,[
 581         rm -f cf_test.out
 582         AC_TRY_RUN([
 583 #include <stdlib.h>
 584 #include <stdio.h>
 585
 586 #if defined(__cplusplus)
 587
 588 #ifdef HAVE_GXX_BUILTIN_H
 589 #include <g++/builtin.h>
 590 #elif HAVE_GPP_BUILTIN_H
 591 #include <gpp/builtin.h>
 592 #elif HAVE_BUILTIN_H
 593 #include <builtin.h>
 594 #endif
 595
 596 #else
 597
 598 #if $cf_cv_header_stdbool_h
 599 #include <stdbool.h>
 600 #endif
 601
 602 #endif
 603
 604 int main(void)
 605 {
 606         FILE *fp = fopen("cf_test.out", "w");
 607         if (fp != 0) {
 608                 bool x = true;
 609                 if ((bool)(-x) >= 0)
 610                         fputs("unsigned ", fp);
 611                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 612                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 613                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 614                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 615                 fclose(fp);
 616         }
 617         ${cf_cv_main_return:-return}(0);
 618 }
 619                 ],
 620                 [cf_cv_type_of_bool=`cat cf_test.out`
 621                  if test -z "$cf_cv_type_of_bool"; then
 622                    cf_cv_type_of_bool=unknown
 623                  fi],
 624                 [cf_cv_type_of_bool=unknown],
 625                 [cf_cv_type_of_bool=unknown])
 626         ])
 627         rm -f cf_test.out
 628 AC_MSG_RESULT($cf_cv_type_of_bool)
 629 if test "$cf_cv_type_of_bool" = unknown ; then
 630         case .$NCURSES_BOOL in
 631         (.auto|.) NCURSES_BOOL=unsigned;;
 632         esac
 633         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 634         cf_cv_type_of_bool=$NCURSES_BOOL
 635 fi
 636 ])dnl
 637 dnl ---------------------------------------------------------------------------
 638 dnl CF_BUILD_CC version: 8 updated: 2018/01/04 20:31:04
 639 dnl -----------
 640 dnl If we're cross-compiling, allow the user to override the tools and their
 641 dnl options.  The configure script is oriented toward identifying the host
 642 dnl compiler, etc., but we need a build compiler to generate parts of the
 643 dnl source.
 644 dnl
 645 dnl $1 = default for $CPPFLAGS
 646 dnl $2 = default for $LIBS
 647 AC_DEFUN([CF_BUILD_CC],[
 648 CF_ACVERSION_CHECK(2.52,,
 649         [AC_REQUIRE([CF_PROG_EXT])])
 650 if test "$cross_compiling" = yes ; then
 651
 652         # defaults that we might want to override
 653         : ${BUILD_CFLAGS:=''}
 654         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 655         : ${BUILD_LDFLAGS:=''}
 656         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 657         : ${BUILD_EXEEXT:='$x'}
 658         : ${BUILD_OBJEXT:='o'}
 659
 660         AC_ARG_WITH(build-cc,
 661                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 662                 [BUILD_CC="$withval"],
 663                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 664         AC_MSG_CHECKING(for native build C compiler)
 665         AC_MSG_RESULT($BUILD_CC)
 666
 667         AC_MSG_CHECKING(for native build C preprocessor)
 668         AC_ARG_WITH(build-cpp,
 669                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 670                 [BUILD_CPP="$withval"],
 671                 [BUILD_CPP='${BUILD_CC} -E'])
 672         AC_MSG_RESULT($BUILD_CPP)
 673
 674         AC_MSG_CHECKING(for native build C flags)
 675         AC_ARG_WITH(build-cflags,
 676                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 677                 [BUILD_CFLAGS="$withval"])
 678         AC_MSG_RESULT($BUILD_CFLAGS)
 679
 680         AC_MSG_CHECKING(for native build C preprocessor-flags)
 681         AC_ARG_WITH(build-cppflags,
 682                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 683                 [BUILD_CPPFLAGS="$withval"])
 684         AC_MSG_RESULT($BUILD_CPPFLAGS)
 685
 686         AC_MSG_CHECKING(for native build linker-flags)
 687         AC_ARG_WITH(build-ldflags,
 688                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 689                 [BUILD_LDFLAGS="$withval"])
 690         AC_MSG_RESULT($BUILD_LDFLAGS)
 691
 692         AC_MSG_CHECKING(for native build linker-libraries)
 693         AC_ARG_WITH(build-libs,
 694                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 695                 [BUILD_LIBS="$withval"])
 696         AC_MSG_RESULT($BUILD_LIBS)
 697
 698         # this assumes we're on Unix.
 699         BUILD_EXEEXT=
 700         BUILD_OBJEXT=o
 701
 702         : ${BUILD_CC:='${CC}'}
 703
 704         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 705                 AC_MSG_ERROR([Cross-build requires two compilers.
 706 Use --with-build-cc to specify the native compiler.])
 707         fi
 708
 709 else
 710         : ${BUILD_CC:='${CC}'}
 711         : ${BUILD_CPP:='${CPP}'}
 712         : ${BUILD_CFLAGS:='${CFLAGS}'}
 713         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 714         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 715         : ${BUILD_LIBS:='${LIBS}'}
 716         : ${BUILD_EXEEXT:='$x'}
 717         : ${BUILD_OBJEXT:='o'}
 718 fi
 719
 720 AC_SUBST(BUILD_CC)
 721 AC_SUBST(BUILD_CPP)
 722 AC_SUBST(BUILD_CFLAGS)
 723 AC_SUBST(BUILD_CPPFLAGS)
 724 AC_SUBST(BUILD_LDFLAGS)
 725 AC_SUBST(BUILD_LIBS)
 726 AC_SUBST(BUILD_EXEEXT)
 727 AC_SUBST(BUILD_OBJEXT)
 728 ])dnl
 729 dnl ---------------------------------------------------------------------------
 730 dnl CF_CC_ENV_FLAGS version: 9 updated: 2018/07/29 18:03:26
 731 dnl ---------------
 732 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 733 dnl into CC.  This will not help with broken scripts that wrap the compiler
 734 dnl with options, but eliminates a more common category of user confusion.
 735 dnl
 736 dnl In particular, it addresses the problem of being able to run the C
 737 dnl preprocessor in a consistent manner.
 738 dnl
 739 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 740 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 741 dnl outweighs that limitation.
 742 AC_DEFUN([CF_CC_ENV_FLAGS],
 743 [
 744 # This should have been defined by AC_PROG_CC
 745 : ${CC:=cc}
 746
 747 AC_MSG_CHECKING(\$CFLAGS variable)
 748 case "x$CFLAGS" in
 749 (*-[[IUD]]*)
 750         AC_MSG_RESULT(broken)
 751         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 752         cf_flags="$CFLAGS"
 753         CFLAGS=
 754         for cf_arg in $cf_flags
 755         do
 756                 CF_ADD_CFLAGS($cf_arg)
 757         done
 758         ;;
 759 (*)
 760         AC_MSG_RESULT(ok)
 761         ;;
 762 esac
 763
 764 AC_MSG_CHECKING(\$CC variable)
 765 case "$CC" in
 766 (*[[\ \ ]]-*)
 767         AC_MSG_RESULT(broken)
 768         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 769         # humor him...
 770         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 771         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 772         CC="$cf_prog"
 773         for cf_arg in $cf_flags
 774         do
 775                 case "x$cf_arg" in
 776                 (x-[[IUDfgOW]]*)
 777                         CF_ADD_CFLAGS($cf_arg)
 778                         ;;
 779                 (*)
 780                         CC="$CC $cf_arg"
 781                         ;;
 782                 esac
 783         done
 784         CF_VERBOSE(resulting CC: '$CC')
 785         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 786         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 787         ;;
 788 (*)
 789         AC_MSG_RESULT(ok)
 790         ;;
 791 esac
 792 ])dnl
 793 dnl ---------------------------------------------------------------------------
 794 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 795 dnl ---------------
 796 dnl Determine the default configuration into which we'll install ncurses.  This
 797 dnl can be overridden by the user's command-line options.  There's two items to
 798 dnl look for:
 799 dnl     1. the prefix (e.g., /usr)
 800 dnl     2. the header files (e.g., /usr/include/ncurses)
 801 dnl We'll look for a previous installation of ncurses and use the same defaults.
 802 dnl
 803 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 804 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 805 dnl programs from a vendor's.
 806 AC_DEFUN([CF_CFG_DEFAULTS],
 807 [
 808 AC_MSG_CHECKING(for prefix)
 809 if test "x$prefix" = "xNONE" ; then
 810         case "$cf_cv_system_name" in
 811                 # non-vendor systems don't have a conflict
 812         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 813                 prefix=/usr
 814                 ;;
 815         (*)     prefix=$ac_default_prefix
 816                 ;;
 817         esac
 818 fi
 819 AC_MSG_RESULT($prefix)
 820
 821 if test "x$prefix" = "xNONE" ; then
 822 AC_MSG_CHECKING(for default include-directory)
 823 test -n "$verbose" && echo 1>&AC_FD_MSG
 824 for cf_symbol in \
 825         $includedir \
 826         $includedir/ncurses \
 827         $prefix/include \
 828         $prefix/include/ncurses \
 829         /usr/local/include \
 830         /usr/local/include/ncurses \
 831         /usr/include \
 832         /usr/include/ncurses
 833 do
 834         cf_dir=`eval echo $cf_symbol`
 835         if test -f $cf_dir/curses.h ; then
 836         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 837                 includedir="$cf_symbol"
 838                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 839                 break
 840         fi
 841         fi
 842         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 843 done
 844 AC_MSG_RESULT($includedir)
 845 fi
 846 ])dnl
 847 dnl ---------------------------------------------------------------------------
 848 dnl CF_CGETENT version: 6 updated: 2017/01/21 11:06:25
 849 dnl ----------
 850 dnl Check if the terminal-capability database functions are available.  If not,
 851 dnl ncurses has a much-reduced version.
 852 AC_DEFUN([CF_CGETENT],[
 853 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 854 AC_TRY_LINK([
 855 #include <stdlib.h>],[
 856         char temp[128];
 857         char *buf = temp;
 858         char *db_array = temp;
 859         cgetent(&buf, &db_array, "vt100");
 860         cgetcap(buf, "tc", '=');
 861         cgetmatch(buf, "tc");
 862         ],
 863         [cf_cv_cgetent=yes],
 864         [cf_cv_cgetent=no])
 865 ])
 866
 867 if test "$cf_cv_cgetent" = yes
 868 then
 869         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 870 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 871 AC_TRY_LINK([
 872 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
 873 #include <stdlib.h>],[
 874         char temp[128];
 875         char *buf = temp;
 876 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 877         const char *db_array = temp;
 878         cgetent(&buf, &db_array, "vt100");
 879 #endif
 880         cgetcap(buf, "tc", '=');
 881         cgetmatch(buf, "tc");
 882         ],
 883         [cf_cv_cgetent_const=yes],
 884         [cf_cv_cgetent_const=no])
 885 ])
 886         if test "$cf_cv_cgetent_const" = yes
 887         then
 888                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 889         fi
 890 fi
 891 ])dnl
 892 dnl ---------------------------------------------------------------------------
 893 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 894 dnl --------------
 895 dnl Check if we're accidentally using a cache from a different machine.
 896 dnl Derive the system name, as a check for reusing the autoconf cache.
 897 dnl
 898 dnl If we've packaged config.guess and config.sub, run that (since it does a
 899 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 900 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 901 dnl which is useful in cross-compiles.
 902 dnl
 903 dnl Note: we would use $ac_config_sub, but that is one of the places where
 904 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 905 AC_DEFUN([CF_CHECK_CACHE],
 906 [
 907 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 908         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 909         system_name="$host_os"
 910 else
 911         system_name="`(uname -s -r) 2>/dev/null`"
 912         if test -z "$system_name" ; then
 913                 system_name="`(hostname) 2>/dev/null`"
 914         fi
 915 fi
 916 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 917 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 918
 919 test -z "$system_name" && system_name="$cf_cv_system_name"
 920 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 921
 922 if test ".$system_name" != ".$cf_cv_system_name" ; then
 923         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 924         AC_MSG_ERROR("Please remove config.cache and try again.")
 925 fi
 926 ])dnl
 927 dnl ---------------------------------------------------------------------------
 928 dnl CF_CHECK_ERRNO version: 12 updated: 2015/04/18 08:56:57
 929 dnl --------------
 930 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 931 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 932 dnl ourselves.
 933 dnl
 934 dnl $1 = the name to check
 935 dnl $2 = the assumed type
 936 AC_DEFUN([CF_CHECK_ERRNO],
 937 [
 938 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 939         AC_TRY_COMPILE([
 940 #ifdef HAVE_STDLIB_H
 941 #include <stdlib.h>
 942 #endif
 943 #include <stdio.h>
 944 #include <sys/types.h>
 945 #include <errno.h> ],
 946         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 947         [cf_cv_dcl_$1=yes],
 948         [cf_cv_dcl_$1=no])
 949 ])
 950
 951 if test "$cf_cv_dcl_$1" = no ; then
 952         CF_UPPER(cf_result,decl_$1)
 953         AC_DEFINE_UNQUOTED($cf_result)
 954 fi
 955
 956 # It's possible (for near-UNIX clones) that the data doesn't exist
 957 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 958 ])dnl
 959 dnl ---------------------------------------------------------------------------
 960 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
 961 dnl --------------------
 962 dnl Check for existence of external data in the current set of libraries.  If
 963 dnl we can modify it, it's real enough.
 964 dnl $1 = the name to check
 965 dnl $2 = its type
 966 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 967 [
 968 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 969         AC_TRY_LINK([
 970 #undef $1
 971 extern $2 $1;
 972 ],
 973         [$1 = 2],
 974         [cf_cv_have_$1=yes],
 975         [cf_cv_have_$1=no])
 976 ])
 977
 978 if test "$cf_cv_have_$1" = yes ; then
 979         CF_UPPER(cf_result,have_$1)
 980         AC_DEFINE_UNQUOTED($cf_result)
 981 fi
 982
 983 ])dnl
 984 dnl ---------------------------------------------------------------------------
 985 dnl CF_CHECK_GPM_WGETCH version: 3 updated: 2017/01/21 11:06:25
 986 dnl -------------------
 987 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 988 dnl is not "weak" - warn about this because it can create problems linking
 989 dnl applications with ncurses.
 990 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 991 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 992
 993 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 994 cf_cv_check_gpm_wgetch=unknown
 995 if test "$cross_compiling" != yes ; then
 996
 997 cat >conftest.$ac_ext <<CF_EOF
 998 #include <gpm.h>
 999 int main(void)
1000 {
1001         Gpm_Wgetch();
1002         ${cf_cv_main_return:-return}(0);
1003 }
1004 CF_EOF
1005
1006         cf_save_LIBS="$LIBS"
1007         # This only works if we can look at the symbol table.  If a shared
1008         # library is stripped for install, we cannot use that.  So we're forced
1009         # to rely on the static library, noting that some packagers may not
1010         # include it.
1011         LIBS="-static -lgpm -dynamic $LIBS"
1012         if AC_TRY_EVAL(ac_compile) ; then
1013                 if AC_TRY_EVAL(ac_link) ; then
1014                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
1015                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
1016                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
1017                 fi
1018         fi
1019         rm -rf conftest*
1020         LIBS="$cf_save_LIBS"
1021 fi
1022 ])
1023
1024 if test "$cf_cv_check_gpm_wgetch" != yes ; then
1025         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
1026 fi
1027 ])])dnl
1028 dnl ---------------------------------------------------------------------------
1029 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
1030 dnl ------------------------
1031 dnl Show the version of libtool
1032 dnl
1033 dnl Save the version in a cache variable - this is not entirely a good thing,
1034 dnl but the version string from libtool is very ugly, and for bug reports it
1035 dnl might be useful to have the original string.
1036 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1037 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1038 then
1039         AC_MSG_CHECKING(version of $LIBTOOL)
1040         CF_LIBTOOL_VERSION
1041         AC_MSG_RESULT($cf_cv_libtool_version)
1042         if test -z "$cf_cv_libtool_version" ; then
1043                 AC_MSG_ERROR(This is not GNU libtool)
1044         fi
1045 else
1046         AC_MSG_ERROR(GNU libtool has not been found)
1047 fi
1048 ])dnl
1049 dnl ---------------------------------------------------------------------------
1050 dnl CF_CHECK_WCHAR_H version: 2 updated: 2017/01/21 11:06:25
1051 dnl ----------------
1052 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1053 AC_DEFUN([CF_CHECK_WCHAR_H],[
1054 AC_CHECK_HEADERS( \
1055 wchar.h \
1056 wctype.h \
1057 )
1058 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1059 AC_TRY_COMPILE(
1060 [
1061 #include <stdlib.h>
1062 #ifdef HAVE_WCHAR_H
1063 #include <wchar.h>
1064 #endif
1065 #ifdef HAVE_WCTYPE_H
1066 #include <wctype.h>
1067 #endif
1068 ],[
1069         wint_t foo = 0;
1070         int bar = iswpunct(foo)],
1071         [cf_cv_wchar_h_okay=yes],
1072         [cf_cv_wchar_h_okay=no])])
1073
1074 if test $cf_cv_wchar_h_okay = no
1075 then
1076         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1077 fi
1078 ])dnl
1079 dnl ---------------------------------------------------------------------------
1080 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 1 updated: 2015/12/19 17:47:56
1081 dnl -------------------------
1082 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1083 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1084 dnl
1085 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1086 dnl all of those were combined into a page of useful graphics characters.
1087 dnl
1088 dnl So far, so good.
1089 dnl
1090 dnl However, while they are useful, there are other considerations.  CJK
1091 dnl is (because of poor device resolution) often rendered as double-width
1092 dnl characters.  So... for these generally-useful characters, what should
1093 dnl be the width (to make them consistent with adjacent characters)?
1094 dnl
1095 dnl The obvious choice would have been to make this locale-dependent, and use
1096 dnl wcwidth() to tell applications what the actual width is.  That was too
1097 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1098 dnl See for example
1099 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1100 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1101 dnl
1102 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1103 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1104 dnl instance, it lists half (44/96) of the Latin-1 characters as
1105 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1106 dnl
1107 dnl What this means for the implementor is that on some systems wcwidth() can
1108 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1109 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1110 dnl characters).  These do not necessarily match the behavior of the terminal
1111 dnl emulator.  xterm, for instance, does an optional startup check to find if
1112 dnl this problem (or similar) exists with the system's locale tables, rejecting
1113 dnl them if they are too unreliable.
1114 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1115 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1116 cat >conftest.in <<CF_EOF
1117 -       VT100 symbols
1118 0x250c  upper left corner
1119 0x2514  lower left corner
1120 0x2510  upper right corner
1121 0x2518  lower right corner
1122 0x251c  tee pointing left
1123 0x2524  tee pointing right
1124 0x2534  tee pointing up
1125 0x252c  tee pointing down
1126 0x2500  horizontal line
1127 0x2502  vertical line
1128 0x253c  large plus or crossover
1129 0x23ba  scan line 1
1130 0x23bd  scan line 9
1131 0x25c6  diamond
1132 0x2592  checker board (stipple)
1133 0x00b0  degree symbol
1134 0x00b1  plus/minus
1135 0x00b7  bullet
1136 -       Teletype 5410v1 symbols
1137 0x2190  arrow pointing left
1138 0x2192  arrow pointing right
1139 0x2193  arrow pointing down
1140 0x2191  arrow pointing up
1141 0x2592  board of squares
1142 0x2603  lantern symbol
1143 0x25ae  solid square block
1144 -       these defaults were invented for ncurses
1145 0x23bb  scan line 3
1146 0x23bc  scan line 7
1147 0x2264  less-than-or-equal-to
1148 0x2265  greater-than-or-equal-to
1149 0x03c0  greek pi
1150 0x2260  not-equal
1151 0x00a3  pound-sterling symbol
1152 -       thick-line-drawing
1153 0x250f  upper left corner
1154 0x2517  lower left corner
1155 0x2513  upper right corner
1156 0x251b  lower right corner
1157 0x2523  tee pointing left
1158 0x252b  tee pointing right
1159 0x253b  tee pointing up
1160 0x2533  tee pointing down
1161 0x2501  horizontal line
1162 0x2503  vertical line
1163 0x254b  large plus or crossover
1164 -       double-line-drawing
1165 0x2554  upper left corner
1166 0x255a  lower left corner
1167 0x2557  upper right corner
1168 0x255d  lower right corner
1169 0x2563  tee pointing left
1170 0x2560  tee pointing right
1171 0x2569  tee pointing up
1172 0x2566  tee pointing down
1173 0x2550  horizontal line
1174 0x2551  vertical line
1175 0x256c  large plus or crossover
1176 CF_EOF
1177 AC_TRY_RUN([
1178 #include <locale.h>
1179 #include <stdio.h>
1180 #include <wchar.h>
1181
1182 #define MY_LEN 80
1183
1184 int
1185 main(void)
1186 {
1187         FILE *fp;
1188         int value;
1189         char buffer[MY_LEN + 1];
1190         char notes[MY_LEN + 1];
1191         int totals = 0;
1192         int passed = 0;
1193
1194         if (setlocale(LC_ALL, "en_US.UTF8") ||
1195                 setlocale(LC_ALL, "en_US.UTF-8") ||
1196                 setlocale(LC_ALL, "en_US.utf8") ||
1197                 setlocale(LC_ALL, "en_US.utf-8")) {
1198                 if ((fp = fopen("conftest.in", "r")) != 0) {
1199                         while (fgets(buffer, MY_LEN, fp) != 0) {
1200                                 if (*buffer == '-') {
1201                                         fprintf(stderr, "\t%s", buffer);
1202                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1203                                         ++totals;
1204                                         if (wcwidth(value) == 1)
1205                                                 ++passed;
1206                                         fprintf(stderr, "%d\t%s", wcwidth(value), buffer);
1207                                 } else {
1208                                         fprintf(stderr, "?\t%s", buffer);
1209                                 }
1210                         }
1211                 }
1212         }
1213         fprintf(stderr, "%d/%d passed wcwidth/graphics check\n", passed, totals);
1214         return (totals == passed) ? 0 : 1;
1215 }
1216 ],
1217 [cf_cv_wcwidth_graphics=yes],
1218 [cf_cv_wcwidth_graphics=no],
1219 [cf_cv_wcwidth_graphics=unknown])
1220 ])
1221 ])dnl
1222 dnl ---------------------------------------------------------------------------
1223 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
1224 dnl -----------------
1225 dnl Check if the given compiler is really clang.  clang's C driver defines
1226 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1227 dnl not ignore some gcc options.
1228 dnl
1229 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1230 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1231 dnl the wrappers for gcc and g++ warnings.
1232 dnl
1233 dnl $1 = GCC (default) or GXX
1234 dnl $2 = CLANG_COMPILER (default)
1235 dnl $3 = CFLAGS (default) or CXXFLAGS
1236 AC_DEFUN([CF_CLANG_COMPILER],[
1237 ifelse([$2],,CLANG_COMPILER,[$2])=no
1238
1239 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1240         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1241         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1242         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
1243         AC_TRY_COMPILE([],[
1244 #ifdef __clang__
1245 #else
1246 make an error
1247 #endif
1248 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1249 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1250 ],[])
1251         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1252         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1253 fi
1254 ])
1255 dnl ---------------------------------------------------------------------------
1256 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1257 dnl -----------------
1258 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1259 dnl is a late feature for the standard and is not in some recent compilers
1260 dnl (1999/9/11).
1261 AC_DEFUN([CF_CPP_PARAM_INIT],
1262 [
1263 if test -n "$CXX"; then
1264 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1265         AC_LANG_SAVE
1266         AC_LANG_CPLUSPLUS
1267         AC_TRY_RUN([
1268 class TEST {
1269 private:
1270         int value;
1271 public:
1272         TEST(int x = 1);
1273         ~TEST();
1274 };
1275
1276 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1277 {
1278         value = x;
1279 }
1280 int main(void) { }
1281 ],
1282         [cf_cv_cpp_param_init=yes],
1283         [cf_cv_cpp_param_init=no],
1284         [cf_cv_cpp_param_init=unknown])
1285         AC_LANG_RESTORE
1286 ])
1287 fi
1288 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1289 ])dnl
1290 dnl ---------------------------------------------------------------------------
1291 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1292 dnl ------------------
1293 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1294 dnl not be supported in g++ before 3.0
1295 AC_DEFUN([CF_CPP_STATIC_CAST],
1296 [
1297 if test -n "$CXX"; then
1298
1299 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1300         AC_LANG_SAVE
1301         AC_LANG_CPLUSPLUS
1302
1303         AC_TRY_COMPILE([
1304 class NCursesPanel
1305 {
1306 public:
1307   NCursesPanel(int nlines,
1308                int ncols,
1309                int begin_y = 0,
1310                int begin_x = 0)
1311   {
1312   }
1313   NCursesPanel();
1314   ~NCursesPanel();
1315 };
1316
1317 template<class T> class NCursesUserPanel : public NCursesPanel
1318 {
1319 public:
1320   NCursesUserPanel (int nlines,
1321                     int ncols,
1322                     int begin_y = 0,
1323                     int begin_x = 0,
1324                     const T* p_UserData = static_cast<T*>(0))
1325     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1326   {
1327   };
1328   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1329   {
1330   };
1331
1332   virtual ~NCursesUserPanel() {};
1333 };
1334 ],[
1335         const char* p_UserData = static_cast<char*>(0)],
1336         [cf_cv_cpp_static_cast=yes],
1337         [cf_cv_cpp_static_cast=no])
1338
1339         AC_LANG_RESTORE
1340 ])
1341
1342 fi
1343
1344 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1345 ])dnl
1346 dnl ---------------------------------------------------------------------------
1347 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1348 dnl ---------------
1349 dnl Setup special archiver flags for given compilers.
1350 AC_DEFUN([CF_CXX_AR_FLAGS],[
1351         CXX_AR='$(AR)'
1352         CXX_ARFLAGS='$(ARFLAGS)'
1353         case $cf_cv_system_name in
1354         (irix*)
1355             if test "$GXX" != yes ; then
1356                 CXX_AR='$(CXX)'
1357                 CXX_ARFLAGS='-ar -o'
1358             fi
1359             ;;
1360         (sco3.2v5*)
1361             CXXLDFLAGS="-u main"
1362             ;;
1363         (solaris2*)
1364             if test "$GXX" != yes ; then
1365                 CXX_AR='$(CXX)'
1366                 CXX_ARFLAGS='-xar -o'
1367             fi
1368             ;;
1369         esac
1370         AC_SUBST(CXXLDFLAGS)
1371         AC_SUBST(CXX_AR)
1372         AC_SUBST(CXX_ARFLAGS)
1373 ])dnl
1374 dnl ---------------------------------------------------------------------------
1375 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1376 dnl -------------------------
1377 dnl For c++, check if iostream uses "std::" namespace.
1378 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1379 AC_CHECK_HEADERS(iostream)
1380 if test x"$ac_cv_header_iostream" = xyes ; then
1381         AC_MSG_CHECKING(if iostream uses std-namespace)
1382         AC_TRY_COMPILE([
1383 #include <iostream>
1384 using std::endl;
1385 using std::cerr;],[
1386 cerr << "testing" << endl;
1387 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1388         AC_MSG_RESULT($cf_iostream_namespace)
1389         if test "$cf_iostream_namespace" = yes ; then
1390                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1391         fi
1392 fi
1393 ])dnl
1394 dnl ---------------------------------------------------------------------------
1395 dnl CF_C_INLINE version: 5 updated: 2015/04/18 08:56:57
1396 dnl -----------
1397 dnl Check if the C compiler supports "inline".
1398 dnl $1 is the name of a shell variable to set if inline is supported
1399 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1400 AC_DEFUN([CF_C_INLINE],[
1401 AC_C_INLINE
1402 $1=
1403 if test "$ac_cv_c_inline" != no ; then
1404         $1=inline
1405         if test "$INTEL_COMPILER" = yes
1406         then
1407                 :
1408         elif test "$CLANG_COMPILER" = yes
1409         then
1410                 :
1411         elif test "$GCC" = yes
1412         then
1413                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1414                 cf_save_CFLAGS=$CFLAGS
1415                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1416                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1417                 [${cf_cv_main_return:-return} foo()],
1418                 [cf_cv_gcc_inline=yes],
1419                 [cf_cv_gcc_inline=no])
1420                 CFLAGS=$cf_save_CFLAGS
1421                 ])
1422                 if test "$cf_cv_gcc_inline" = yes ; then
1423                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1424                 fi
1425         fi
1426 fi
1427 AC_SUBST($1)
1428 ])dnl
1429 dnl ---------------------------------------------------------------------------
1430 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1431 dnl ----------
1432 dnl "dirname" is not portable, so we fake it with a shell script.
1433 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1434 dnl ---------------------------------------------------------------------------
1435 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1436 dnl ---------------
1437 AC_DEFUN([CF_DIRS_TO_MAKE],
1438 [
1439 DIRS_TO_MAKE="lib"
1440 for cf_item in $cf_list_models
1441 do
1442         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1443         for cf_item2 in $DIRS_TO_MAKE
1444         do
1445                 test $cf_item2 = $cf_subdir && break
1446         done
1447         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1448 done
1449 for cf_dir in $DIRS_TO_MAKE
1450 do
1451         test ! -d $cf_dir && mkdir $cf_dir
1452 done
1453 AC_SUBST(DIRS_TO_MAKE)
1454 ])dnl
1455 dnl ---------------------------------------------------------------------------
1456 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1457 dnl ---------------
1458 dnl You can always use "make -n" to see the actual options, but it's hard to
1459 dnl pick out/analyze warning messages when the compile-line is long.
1460 dnl
1461 dnl Sets:
1462 dnl     ECHO_LT - symbol to control if libtool is verbose
1463 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1464 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1465 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1466 dnl     ECHO_CC - symbol to put before any "cc" line
1467 dnl
1468 AC_DEFUN([CF_DISABLE_ECHO],[
1469 AC_MSG_CHECKING(if you want to see long compiling messages)
1470 CF_ARG_DISABLE(echo,
1471         [  --disable-echo          do not display "compiling" commands],
1472         [
1473         ECHO_LT='--silent'
1474         ECHO_LD='@echo linking [$]@;'
1475         RULE_CC='@echo compiling [$]<'
1476         SHOW_CC='@echo compiling [$]@'
1477         ECHO_CC='@'
1478 ],[
1479         ECHO_LT=''
1480         ECHO_LD=''
1481         RULE_CC=''
1482         SHOW_CC=''
1483         ECHO_CC=''
1484 ])
1485 AC_MSG_RESULT($enableval)
1486 AC_SUBST(ECHO_LT)
1487 AC_SUBST(ECHO_LD)
1488 AC_SUBST(RULE_CC)
1489 AC_SUBST(SHOW_CC)
1490 AC_SUBST(ECHO_CC)
1491 ])dnl
1492 dnl ---------------------------------------------------------------------------
1493 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1494 dnl ------------------------
1495 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1496 AC_MSG_CHECKING(if we want to use GNAT projects)
1497 CF_ARG_DISABLE(gnat-projects,
1498         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1499         [enable_gnat_projects=no],
1500         [enable_gnat_projects=yes])
1501 AC_MSG_RESULT($enable_gnat_projects)
1502 ])dnl
1503 dnl ---------------------------------------------------------------------------
1504 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1505 dnl ----------------
1506 dnl Combine no-leak checks with the libraries or tools that are used for the
1507 dnl checks.
1508 AC_DEFUN([CF_DISABLE_LEAKS],[
1509
1510 AC_REQUIRE([CF_WITH_DMALLOC])
1511 AC_REQUIRE([CF_WITH_DBMALLOC])
1512 AC_REQUIRE([CF_WITH_VALGRIND])
1513
1514 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1515 AC_ARG_ENABLE(leaks,
1516         [  --disable-leaks         test: free permanent memory, analyze leaks],
1517         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1518         : ${with_no_leaks:=no})
1519 AC_MSG_RESULT($with_no_leaks)
1520
1521 if test "$with_no_leaks" = yes ; then
1522         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1523         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1524 fi
1525 ])dnl
1526 dnl ---------------------------------------------------------------------------
1527 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1528 dnl --------------------------
1529 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1530 dnl the older "-version-info" feature.  The newer feature allows us to use
1531 dnl version numbering on shared libraries which make them compatible with
1532 dnl various systems.
1533 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1534 [
1535 AC_MSG_CHECKING(if libtool -version-number should be used)
1536 CF_ARG_DISABLE(libtool-version,
1537         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1538         [cf_libtool_version=no],
1539         [cf_libtool_version=yes])
1540 AC_MSG_RESULT($cf_libtool_version)
1541
1542 if test "$cf_libtool_version" = yes ; then
1543         LIBTOOL_VERSION="-version-number"
1544 else
1545         LIBTOOL_VERSION="-version-info"
1546         case "x$VERSION" in
1547         (x)
1548                 AC_MSG_WARN(VERSION was not set)
1549                 ;;
1550         (x*.*.*)
1551                 ABI_VERSION="$VERSION"
1552                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1553                 ;;
1554         (x*:*:*)
1555                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1556                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1557                 ;;
1558         (*)
1559                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1560                 ;;
1561         esac
1562 fi
1563
1564 AC_SUBST(ABI_VERSION)
1565 AC_SUBST(LIBTOOL_VERSION)
1566 ])dnl
1567 dnl ---------------------------------------------------------------------------
1568 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1569 dnl ---------------------
1570 dnl The rpath-hack makes it simpler to build programs, particularly with the
1571 dnl *BSD ports which may have essential libraries in unusual places.  But it
1572 dnl can interfere with building an executable for the base system.  Use this
1573 dnl option in that case.
1574 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1575 [
1576 AC_MSG_CHECKING(if rpath-hack should be disabled)
1577 CF_ARG_DISABLE(rpath-hack,
1578         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1579         [cf_disable_rpath_hack=yes],
1580         [cf_disable_rpath_hack=no])
1581 AC_MSG_RESULT($cf_disable_rpath_hack)
1582 if test "$cf_disable_rpath_hack" = no ; then
1583         CF_RPATH_HACK
1584 fi
1585 ])
1586 dnl ---------------------------------------------------------------------------
1587 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
1588 dnl ------------------
1589 dnl This is the "--enable-pc-files" option, which is available if there is a
1590 dnl pkg-config configuration on the local machine.
1591 AC_DEFUN([CF_ENABLE_PC_FILES],[
1592 AC_REQUIRE([CF_PKG_CONFIG])
1593 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1594
1595 if test "x$PKG_CONFIG" != xnone
1596 then
1597         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1598 else
1599         AC_MSG_CHECKING(if we should install .pc files)
1600 fi
1601
1602 AC_ARG_ENABLE(pc-files,
1603         [  --enable-pc-files       generate and install .pc files for pkg-config],
1604         [enable_pc_files=$enableval],
1605         [enable_pc_files=no])
1606 AC_MSG_RESULT($enable_pc_files)
1607
1608 if test "x$enable_pc_files" != xno
1609 then
1610         MAKE_PC_FILES=
1611         case "x$PKG_CONFIG_LIBDIR" in
1612         (xno|xyes)
1613                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1614                 ;;
1615         (*)
1616                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1617                 ;;
1618         esac
1619 else
1620         MAKE_PC_FILES="#"
1621 fi
1622 AC_SUBST(MAKE_PC_FILES)
1623 ])dnl
1624 dnl ---------------------------------------------------------------------------
1625 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1626 dnl ---------------
1627 dnl Check if the rpath option should be used, setting cache variable
1628 dnl cf_cv_enable_rpath if so.
1629 AC_DEFUN([CF_ENABLE_RPATH],
1630 [
1631 AC_MSG_CHECKING(if rpath option should be used)
1632 AC_ARG_ENABLE(rpath,
1633 [  --enable-rpath          use rpath option when generating shared libraries],
1634 [cf_cv_enable_rpath=$enableval],
1635 [cf_cv_enable_rpath=no])
1636 AC_MSG_RESULT($cf_cv_enable_rpath)
1637 ])dnl
1638 dnl ---------------------------------------------------------------------------
1639 dnl CF_ENABLE_STRING_HACKS version: 5 updated: 2016/10/08 17:34:11
1640 dnl ----------------------
1641 dnl On a few platforms, the compiler and/or loader nags with untruthful
1642 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1643 dnl and implying that most uses of the recommended alternatives are correct.
1644 dnl
1645 dnl Factually speaking, no one has actually counted the number of uses of these
1646 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1647 dnl instances are meaningless compared to the hundreds of millions of lines of
1648 dnl existing C code.
1649 dnl
1650 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1651 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1652 dnl standard - but evolved through phases, and older implementations are likely
1653 dnl to yield surprising results, as documented in manpages on various systems.
1654 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1655 [
1656 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1657 AC_ARG_ENABLE(string-hacks,
1658         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1659         [with_string_hacks=$enableval],
1660         [with_string_hacks=no])
1661 AC_MSG_RESULT($with_string_hacks)
1662
1663 if test "x$with_string_hacks" = "xyes"; then
1664         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1665         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1666         AC_CHECK_FUNC(strlcat,[
1667                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1668                 ],[
1669                 AC_CHECK_LIB(bsd,strlcat,[
1670                         CF_ADD_LIB(bsd)
1671                         AC_CHECK_HEADERS(bsd/string.h)
1672                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1673                         ])
1674                 ])
1675         AC_CHECK_FUNCS( strlcpy snprintf )
1676 fi
1677 ])dnl
1678 dnl ---------------------------------------------------------------------------
1679 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1680 dnl --------
1681 dnl Check if 'errno' is declared in <errno.h>
1682 AC_DEFUN([CF_ERRNO],
1683 [
1684 CF_CHECK_ERRNO(errno)
1685 ])dnl
1686 dnl ---------------------------------------------------------------------------
1687 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1688 dnl ---------------
1689 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1690 dnl math.h and builtin.h, only for ncurses
1691 AC_DEFUN([CF_ETIP_DEFINES],
1692 [
1693 AC_MSG_CHECKING(for special defines needed for etip.h)
1694 cf_save_CXXFLAGS="$CXXFLAGS"
1695 cf_result="none"
1696
1697 # etip.h includes ncurses.h which includes ncurses_dll.h
1698 # But ncurses_dll.h is generated - fix here.
1699 test -d include || mkdir include
1700 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1701
1702 for cf_math in "" MATH_H
1703 do
1704 for cf_excp in "" MATH_EXCEPTION
1705 do
1706         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1707         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1708         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1709 AC_TRY_COMPILE([
1710 #include <etip.h.in>
1711 ],[],[
1712         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1713         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1714         cf_result="$cf_math $cf_excp"
1715         break 2
1716 ],[])
1717 done
1718 done
1719 AC_MSG_RESULT($cf_result)
1720 CXXFLAGS="$cf_save_CXXFLAGS"
1721 ])
1722 dnl ---------------------------------------------------------------------------
1723 dnl CF_FIND_LINKAGE version: 21 updated: 2018/06/20 20:23:13
1724 dnl ---------------
1725 dnl Find a library (specifically the linkage used in the code fragment),
1726 dnl searching for it if it is not already in the library path.
1727 dnl See also CF_ADD_SEARCHPATH.
1728 dnl
1729 dnl Parameters (4-on are optional):
1730 dnl     $1 = headers for library entrypoint
1731 dnl     $2 = code fragment for library entrypoint
1732 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1733 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1734 dnl     $5 = action to perform if not successful
1735 dnl     $6 = module name, if not the same as the library name
1736 dnl     $7 = extra libraries
1737 dnl
1738 dnl Sets these variables:
1739 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1740 dnl     $cf_cv_header_path_$3 - include-directory if needed
1741 dnl     $cf_cv_library_path_$3 - library-directory if needed
1742 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1743 AC_DEFUN([CF_FIND_LINKAGE],[
1744
1745 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1746 # will be set on completion of the AC_TRY_LINK below.
1747 cf_cv_header_path_$3=
1748 cf_cv_library_path_$3=
1749
1750 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1751
1752 cf_save_LIBS="$LIBS"
1753
1754 AC_TRY_LINK([$1],[$2],[
1755         cf_cv_find_linkage_$3=yes
1756         cf_cv_header_path_$3=/usr/include
1757         cf_cv_library_path_$3=/usr/lib
1758 ],[
1759
1760 LIBS="-l$3 $7 $cf_save_LIBS"
1761
1762 AC_TRY_LINK([$1],[$2],[
1763         cf_cv_find_linkage_$3=yes
1764         cf_cv_header_path_$3=/usr/include
1765         cf_cv_library_path_$3=/usr/lib
1766         cf_cv_library_file_$3="-l$3"
1767 ],[
1768         cf_cv_find_linkage_$3=no
1769         LIBS="$cf_save_LIBS"
1770
1771         CF_VERBOSE(find linkage for $3 library)
1772         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1773
1774         cf_save_CPPFLAGS="$CPPFLAGS"
1775         cf_test_CPPFLAGS="$CPPFLAGS"
1776
1777         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1778         for cf_cv_header_path_$3 in $cf_search
1779         do
1780                 if test -d $cf_cv_header_path_$3 ; then
1781                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1782                         CPPFLAGS="$cf_save_CPPFLAGS"
1783                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
1784                         AC_TRY_COMPILE([$1],[$2],[
1785                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1786                                 cf_cv_find_linkage_$3=maybe
1787                                 cf_test_CPPFLAGS="$CPPFLAGS"
1788                                 break],[
1789                                 CPPFLAGS="$cf_save_CPPFLAGS"
1790                                 ])
1791                 fi
1792         done
1793
1794         if test "$cf_cv_find_linkage_$3" = maybe ; then
1795
1796                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1797
1798                 cf_save_LIBS="$LIBS"
1799                 cf_save_LDFLAGS="$LDFLAGS"
1800
1801                 ifelse([$6],,,[
1802                 CPPFLAGS="$cf_test_CPPFLAGS"
1803                 LIBS="-l$3 $7 $cf_save_LIBS"
1804                 AC_TRY_LINK([$1],[$2],[
1805                         CF_VERBOSE(... found $3 library in system)
1806                         cf_cv_find_linkage_$3=yes])
1807                         CPPFLAGS="$cf_save_CPPFLAGS"
1808                         LIBS="$cf_save_LIBS"
1809                         ])
1810
1811                 if test "$cf_cv_find_linkage_$3" != yes ; then
1812                         CF_LIBRARY_PATH(cf_search,$3)
1813                         for cf_cv_library_path_$3 in $cf_search
1814                         do
1815                                 if test -d $cf_cv_library_path_$3 ; then
1816                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1817                                         CPPFLAGS="$cf_test_CPPFLAGS"
1818                                         LIBS="-l$3 $7 $cf_save_LIBS"
1819                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1820                                         AC_TRY_LINK([$1],[$2],[
1821                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1822                                         cf_cv_find_linkage_$3=yes
1823                                         cf_cv_library_file_$3="-l$3"
1824                                         break],[
1825                                         CPPFLAGS="$cf_save_CPPFLAGS"
1826                                         LIBS="$cf_save_LIBS"
1827                                         LDFLAGS="$cf_save_LDFLAGS"
1828                                         ])
1829                                 fi
1830                         done
1831                         CPPFLAGS="$cf_save_CPPFLAGS"
1832                         LDFLAGS="$cf_save_LDFLAGS"
1833                 fi
1834
1835         else
1836                 cf_cv_find_linkage_$3=no
1837         fi
1838         ],$7)
1839 ])
1840
1841 LIBS="$cf_save_LIBS"
1842
1843 if test "$cf_cv_find_linkage_$3" = yes ; then
1844 ifelse([$4],,[
1845         CF_ADD_INCDIR($cf_cv_header_path_$3)
1846         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1847         CF_ADD_LIB($3)
1848 ],[$4])
1849 else
1850 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1851 fi
1852 ])dnl
1853 dnl ---------------------------------------------------------------------------
1854 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
1855 dnl ------------------
1856 dnl Find an include-directory with the given leaf-name.  This is useful for
1857 dnl example with FreeBSD ports, which use this convention to distinguish
1858 dnl different versions of the same port.
1859 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1860         CF_SUBDIR_PATH(cf_search,$1,include)
1861         for cf_item in $cf_search
1862         do
1863                 case $cf_item in
1864                 (*/$1)
1865                         CF_ADD_INCDIR($cf_item)
1866                         ;;
1867                 esac
1868         done
1869 ])dnl
1870 dnl ---------------------------------------------------------------------------
1871 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
1872 dnl ------------------
1873 dnl Find a library-directory with the given leaf-name.  This is useful for
1874 dnl example with FreeBSD ports, which use this convention to distinguish
1875 dnl different versions of the same port.
1876 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1877         CF_SUBDIR_PATH(cf_search,$1,lib)
1878         for cf_item in $cf_search
1879         do
1880                 case $cf_item in
1881                 (*/$1)
1882                         CF_ADD_LIBDIR($cf_item)
1883                         ;;
1884                 esac
1885         done
1886 ])dnl
1887 dnl ---------------------------------------------------------------------------
1888 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1889 dnl -----------------
1890 dnl make ADAFLAGS consistent with CFLAGS
1891 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1892         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1893         case "$CFLAGS" in
1894         (*-g*)
1895                 CF_ADD_ADAFLAGS(-g)
1896                 ;;
1897         esac
1898         case "$CFLAGS" in
1899         (*-O*)
1900                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1901                 CF_ADD_ADAFLAGS($cf_O_flag)
1902                 ;;
1903         esac
1904         AC_MSG_RESULT($ADAFLAGS)
1905 ])dnl
1906 dnl ---------------------------------------------------------------------------
1907 dnl CF_FOPEN_BIN_R version: 1 updated: 2019/03/30 17:52:21
1908 dnl --------------
1909 dnl Check if fopen works when the "b" (binary) flag is added to the mode
1910 dnl parameter.  POSIX ignores the "b", which c89 specified.  Some very old
1911 dnl systems do not accept it.
1912 AC_DEFUN([CF_FOPEN_BIN_R],[
1913 AC_CACHE_CHECK(if fopen accepts explicit binary mode,cf_cv_fopen_bin_r,[
1914         AC_TRY_RUN([
1915 #include <stdio.h>
1916 int main(void) {
1917         FILE *fp = fopen("conftest.tmp", "wb");
1918         int rc = 0;
1919         if (fp != 0) {
1920                 int p, q;
1921                 for (p = 0; p < 256; ++p) {
1922                         fputc(p, fp);
1923                 }
1924                 fclose(fp);
1925                 fp = fopen("conftest.tmp", "rb");
1926                 if (fp != 0) {
1927                         for (p = 0; p < 256; ++p) {
1928                                 q = fgetc(fp);
1929                                 if (q != p) {
1930                                         rc = 1;
1931                                         break;
1932                                 }
1933                         }
1934                 } else {
1935                         rc = 1;
1936                 }
1937         } else {
1938                 rc = 1;
1939         }
1940         ${cf_cv_main_return:-return} (rc);
1941 }
1942 ],
1943                 [cf_cv_fopen_bin_r=yes],
1944                 [cf_cv_fopen_bin_r=no],
1945                 [cf_cv_fopen_bin_r=unknown])
1946 ])
1947 test "x$cf_cv_fopen_bin_r" != xno && AC_DEFINE(USE_FOPEN_BIN_R)
1948 ])dnl
1949 dnl ---------------------------------------------------------------------------
1950 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1951 dnl --------------
1952 dnl Forget that we saw the given tool.
1953 AC_DEFUN([CF_FORGET_TOOL],[
1954 unset ac_cv_prog_ac_ct_$1
1955 unset ac_ct_$1
1956 unset $1
1957 ])dnl
1958 dnl ---------------------------------------------------------------------------
1959 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
1960 dnl -------------
1961 dnl Test for dlsym() and related functions, as well as libdl.
1962 dnl
1963 dnl Sets
1964 dnl     $cf_have_dlsym
1965 dnl     $cf_have_libdl
1966 AC_DEFUN([CF_FUNC_DLSYM],[
1967 cf_have_dlsym=no
1968 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1969
1970 cf_have_libdl=no
1971 AC_CHECK_LIB(dl,dlsym,[
1972         cf_have_dlsym=yes
1973         cf_have_libdl=yes])])
1974
1975 if test "$cf_have_dlsym" = yes ; then
1976         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
1977
1978         AC_MSG_CHECKING(whether able to link to dl*() functions)
1979         AC_TRY_LINK([#include <dlfcn.h>],[
1980                 void *obj;
1981                 if ((obj = dlopen("filename", 0)) != 0) {
1982                         if (dlsym(obj, "symbolname") == 0) {
1983                         dlclose(obj);
1984                         }
1985                 }],[
1986                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1987                 AC_MSG_ERROR(Cannot link test program for libdl)])
1988         AC_MSG_RESULT(ok)
1989 else
1990         AC_MSG_ERROR(Cannot find dlsym function)
1991 fi
1992 ])
1993 dnl ---------------------------------------------------------------------------
1994 dnl CF_FUNC_MEMMOVE version: 9 updated: 2017/01/21 11:06:25
1995 dnl ---------------
1996 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1997 dnl is found, add our own version of memmove to the list of objects.
1998 AC_DEFUN([CF_FUNC_MEMMOVE],
1999 [
2000 AC_CHECK_FUNC(memmove,,[
2001 AC_CHECK_FUNC(bcopy,[
2002         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
2003                 AC_TRY_RUN([
2004 int main(void) {
2005         static char data[] = "abcdefghijklmnopqrstuwwxyz";
2006         char temp[40];
2007         bcopy(data, temp, sizeof(data));
2008         bcopy(temp+10, temp, 15);
2009         bcopy(temp+5, temp+15, 10);
2010         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
2011 }
2012                 ],
2013                 [cf_cv_good_bcopy=yes],
2014                 [cf_cv_good_bcopy=no],
2015                 [cf_cv_good_bcopy=unknown])
2016                 ])
2017         ],[cf_cv_good_bcopy=no])
2018         if test "$cf_cv_good_bcopy" = yes ; then
2019                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
2020         else
2021                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
2022         fi
2023 ])])dnl
2024 dnl ---------------------------------------------------------------------------
2025 dnl CF_FUNC_NANOSLEEP version: 5 updated: 2017/01/21 11:06:25
2026 dnl -----------------
2027 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
2028 dnl AIX 4.x, provide a non-working version.
2029 AC_DEFUN([CF_FUNC_NANOSLEEP],[
2030 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
2031 AC_TRY_RUN([
2032 #include <stdio.h>
2033 #include <errno.h>
2034 #include <time.h>
2035
2036 #ifdef HAVE_SYS_TIME_H
2037 #include <sys/time.h>
2038 #endif
2039
2040 int main(void) {
2041         struct timespec ts1, ts2;
2042         int code;
2043         ts1.tv_sec  = 0;
2044         ts1.tv_nsec = 750000000;
2045         ts2.tv_sec  = 0;
2046         ts2.tv_nsec = 0;
2047         errno = 0;
2048         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
2049         ${cf_cv_main_return:-return}(code != 0);
2050 }
2051 ],
2052         [cf_cv_func_nanosleep=yes],
2053         [cf_cv_func_nanosleep=no],
2054         [cf_cv_func_nanosleep=unknown])])
2055
2056 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
2057 ])
2058 dnl ---------------------------------------------------------------------------
2059 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
2060 dnl ---------------
2061 dnl Check for openpty() function, along with <pty.h> header.  It may need the
2062 dnl "util" library as well.
2063 AC_DEFUN([CF_FUNC_OPENPTY],
2064 [
2065 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
2066 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
2067         cf_save_LIBS="$LIBS"
2068         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
2069         for cf_header in pty.h libutil.h util.h
2070         do
2071         AC_TRY_LINK([
2072 #include <$cf_header>
2073 ],[
2074         int x = openpty((int *)0, (int *)0, (char *)0,
2075                                    (struct termios *)0, (struct winsize *)0);
2076 ],[
2077                 cf_cv_func_openpty=$cf_header
2078                 break
2079 ],[
2080                 cf_cv_func_openpty=no
2081 ])
2082         done
2083         LIBS="$cf_save_LIBS"
2084 ])
2085 ])dnl
2086 dnl ---------------------------------------------------------------------------
2087 dnl CF_FUNC_POLL version: 9 updated: 2015/10/10 13:27:32
2088 dnl ------------
2089 dnl See if the poll function really works.  Some platforms have poll(), but
2090 dnl it does not work for terminals or files.
2091 AC_DEFUN([CF_FUNC_POLL],[
2092 tty 2>&1 >/dev/null || { AC_CHECK_FUNCS(posix_openpt) }
2093 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2094 AC_TRY_RUN([
2095 #include <stdlib.h>
2096 #include <stdio.h>
2097 #include <unistd.h>
2098 #include <fcntl.h>
2099 #ifdef HAVE_POLL_H
2100 #include <poll.h>
2101 #else
2102 #include <sys/poll.h>
2103 #endif
2104 int main(void) {
2105         struct pollfd myfds;
2106         int ret;
2107
2108         /* check for Darwin bug with respect to "devices" */
2109         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2110         if (myfds.fd < 0)
2111                 myfds.fd = 0;
2112         myfds.events = POLLIN;
2113         myfds.revents = 0;
2114
2115         ret = poll(&myfds, 1, 100);
2116
2117         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2118                 ret = -1;
2119         } else {
2120                 int fd = 0;
2121                 if (!isatty(fd)) {
2122                         fd = open("/dev/tty", 2);       /* O_RDWR */
2123                 }
2124 #ifdef HAVE_POSIX_OPENPT
2125                 if (fd < 0) {
2126                         fd = posix_openpt(O_RDWR);
2127                 }
2128 #endif
2129
2130                 if (fd >= 0) {
2131                         /* also check with standard input */
2132                         myfds.fd = fd;
2133                         myfds.events = POLLIN;
2134                         myfds.revents = 0;
2135                         ret = poll(&myfds, 1, 100);
2136                 } else {
2137                         ret = -1;
2138                 }
2139         }
2140         ${cf_cv_main_return:-return}(ret < 0);
2141 }],
2142         [cf_cv_working_poll=yes],
2143         [cf_cv_working_poll=no],
2144         [cf_cv_working_poll=unknown])])
2145 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2146 ])dnl
2147 dnl ---------------------------------------------------------------------------
2148 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2149 dnl ---------------
2150 dnl Some old/broken variations define tcgetattr() only as a macro in
2151 dnl termio(s).h
2152 AC_DEFUN([CF_FUNC_TERMIOS],[
2153 AC_REQUIRE([CF_STRUCT_TERMIOS])
2154 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2155 AC_TRY_LINK([
2156 #include <sys/types.h>
2157 #ifdef HAVE_UNISTD_H
2158 #include <unistd.h>
2159 #endif
2160 #ifdef HAVE_TERMIOS_H
2161 #include <termios.h>
2162 #define TTY struct termios
2163 #else
2164 #ifdef HAVE_TERMIO_H
2165 #include <termio.h>
2166 #define TTY struct termio
2167 #endif
2168 #endif
2169 ],[
2170 TTY foo;
2171 tcgetattr(1, &foo);],
2172 [cf_cv_have_tcgetattr=yes],
2173 [cf_cv_have_tcgetattr=no])])
2174 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2175 ])dnl
2176 dnl ---------------------------------------------------------------------------
2177 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
2178 dnl ---------------
2179 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2180 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2181 dnl other functions.
2182 AC_DEFUN([CF_FUNC_VSSCANF],
2183 [
2184 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2185 AC_TRY_LINK([
2186 #include <stdarg.h>
2187 #include <stdio.h>],[
2188         va_list ap;
2189         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2190 AC_TRY_LINK([
2191 #include <stdarg.h>
2192 #include <stdio.h>],[
2193         FILE strbuf;
2194         char *str = "from";
2195
2196         strbuf._flag = _IOREAD;
2197         strbuf._ptr = strbuf._base = (unsigned char *) str;
2198         strbuf._cnt = strlen(str);
2199         strbuf._file = _NFILE;
2200         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2201 AC_TRY_LINK([
2202 #include <stdarg.h>
2203 #include <stdio.h>],[
2204         FILE strbuf;
2205         char *str = "from";
2206
2207         strbuf._flag = _IOREAD;
2208         strbuf._ptr = strbuf._base = (unsigned char *) str;
2209         strbuf._cnt = strlen(str);
2210         strbuf._file = _NFILE;
2211         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2212 cf_cv_func_vsscanf=no])])])])
2213
2214 case $cf_cv_func_vsscanf in
2215 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2216 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2217 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2218 esac
2219
2220 ])dnl
2221 dnl ---------------------------------------------------------------------------
2222 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
2223 dnl -----------------
2224 dnl Test for availability of useful gcc __attribute__ directives to quiet
2225 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2226 dnl to documentation, unrecognized directives cause older compilers to barf.
2227 AC_DEFUN([CF_GCC_ATTRIBUTES],
2228 [
2229 if test "$GCC" = yes
2230 then
2231 cat > conftest.i <<EOF
2232 #ifndef GCC_PRINTF
2233 #define GCC_PRINTF 0
2234 #endif
2235 #ifndef GCC_SCANF
2236 #define GCC_SCANF 0
2237 #endif
2238 #ifndef GCC_NORETURN
2239 #define GCC_NORETURN /* nothing */
2240 #endif
2241 #ifndef GCC_UNUSED
2242 #define GCC_UNUSED /* nothing */
2243 #endif
2244 EOF
2245 if test "$GCC" = yes
2246 then
2247         AC_CHECKING([for $CC __attribute__ directives])
2248 cat > conftest.$ac_ext <<EOF
2249 #line __oline__ "${as_me:-configure}"
2250 #include "confdefs.h"
2251 #include "conftest.h"
2252 #include "conftest.i"
2253 #if     GCC_PRINTF
2254 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2255 #else
2256 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2257 #endif
2258 #if     GCC_SCANF
2259 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2260 #else
2261 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2262 #endif
2263 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2264 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
2265 extern void foo(void) GCC_NORETURN;
2266 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
2267 EOF
2268         cf_printf_attribute=no
2269         cf_scanf_attribute=no
2270         for cf_attribute in scanf printf unused noreturn
2271         do
2272                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2273                 cf_directive="__attribute__(($cf_attribute))"
2274                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2275
2276                 case $cf_attribute in
2277                 (printf)
2278                         cf_printf_attribute=yes
2279                         cat >conftest.h <<EOF
2280 #define GCC_$cf_ATTRIBUTE 1
2281 EOF
2282                         ;;
2283                 (scanf)
2284                         cf_scanf_attribute=yes
2285                         cat >conftest.h <<EOF
2286 #define GCC_$cf_ATTRIBUTE 1
2287 EOF
2288                         ;;
2289                 (*)
2290                         cat >conftest.h <<EOF
2291 #define GCC_$cf_ATTRIBUTE $cf_directive
2292 EOF
2293                         ;;
2294                 esac
2295
2296                 if AC_TRY_EVAL(ac_compile); then
2297                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2298                         cat conftest.h >>confdefs.h
2299                         case $cf_attribute in
2300                         (noreturn)
2301                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2302                                 ;;
2303                         (printf)
2304                                 cf_value='/* nothing */'
2305                                 if test "$cf_printf_attribute" != no ; then
2306                                         cf_value='__attribute__((format(printf,fmt,var)))'
2307                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2308                                 fi
2309                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2310                                 ;;
2311                         (scanf)
2312                                 cf_value='/* nothing */'
2313                                 if test "$cf_scanf_attribute" != no ; then
2314                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2315                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2316                                 fi
2317                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2318                                 ;;
2319                         (unused)
2320                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2321                                 ;;
2322                         esac
2323                 fi
2324         done
2325 else
2326         fgrep define conftest.i >>confdefs.h
2327 fi
2328 rm -rf conftest*
2329 fi
2330 ])dnl
2331 dnl ---------------------------------------------------------------------------
2332 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
2333 dnl --------------
2334 dnl Find version of gcc
2335 AC_DEFUN([CF_GCC_VERSION],[
2336 AC_REQUIRE([AC_PROG_CC])
2337 GCC_VERSION=none
2338 if test "$GCC" = yes ; then
2339         AC_MSG_CHECKING(version of $CC)
2340         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2341         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2342         AC_MSG_RESULT($GCC_VERSION)
2343 fi
2344 ])dnl
2345 dnl ---------------------------------------------------------------------------
2346 dnl CF_GCC_WARNINGS version: 33 updated: 2018/06/20 20:23:13
2347 dnl ---------------
2348 dnl Check if the compiler supports useful warning options.  There's a few that
2349 dnl we don't use, simply because they're too noisy:
2350 dnl
2351 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2352 dnl     -Wredundant-decls (system headers make this too noisy)
2353 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2354 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2355 dnl             is enabled for ncurses using "--enable-const".
2356 dnl     -pedantic
2357 dnl
2358 dnl Parameter:
2359 dnl     $1 is an optional list of gcc warning flags that a particular
2360 dnl             application might want to use, e.g., "no-unused" for
2361 dnl             -Wno-unused
2362 dnl Special:
2363 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2364 dnl
2365 AC_DEFUN([CF_GCC_WARNINGS],
2366 [
2367 AC_REQUIRE([CF_GCC_VERSION])
2368 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2369 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2370
2371 cat > conftest.$ac_ext <<EOF
2372 #line __oline__ "${as_me:-configure}"
2373 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2374 EOF
2375
2376 if test "$INTEL_COMPILER" = yes
2377 then
2378 # The "-wdXXX" options suppress warnings:
2379 # remark #1419: external declaration in primary source file
2380 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2381 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2382 # remark #193: zero used for undefined preprocessing identifier
2383 # remark #593: variable "curs_sb_left_arrow" was set but never used
2384 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2385 # remark #869: parameter "tw" was never referenced
2386 # remark #981: operands are evaluated in unspecified order
2387 # warning #279: controlling expression is constant
2388
2389         AC_CHECKING([for $CC warning options])
2390         cf_save_CFLAGS="$CFLAGS"
2391         EXTRA_CFLAGS="-Wall"
2392         for cf_opt in \
2393                 wd1419 \
2394                 wd1683 \
2395                 wd1684 \
2396                 wd193 \
2397                 wd593 \
2398                 wd279 \
2399                 wd810 \
2400                 wd869 \
2401                 wd981
2402         do
2403                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2404                 if AC_TRY_EVAL(ac_compile); then
2405                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2406                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2407                 fi
2408         done
2409         CFLAGS="$cf_save_CFLAGS"
2410
2411 elif test "$GCC" = yes
2412 then
2413         AC_CHECKING([for $CC warning options])
2414         cf_save_CFLAGS="$CFLAGS"
2415         EXTRA_CFLAGS=
2416         cf_warn_CONST=""
2417         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2418         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2419         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2420         for cf_opt in W Wall \
2421                 Wbad-function-cast \
2422                 Wcast-align \
2423                 Wcast-qual \
2424                 Wdeclaration-after-statement \
2425                 Wextra \
2426                 Winline \
2427                 Wmissing-declarations \
2428                 Wmissing-prototypes \
2429                 Wnested-externs \
2430                 Wpointer-arith \
2431                 Wshadow \
2432                 Wstrict-prototypes \
2433                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2434         do
2435                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2436                 if AC_TRY_EVAL(ac_compile); then
2437                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2438                         case $cf_opt in
2439                         (Wcast-qual)
2440                                 CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
2441                                 ;;
2442                         (Winline)
2443                                 case $GCC_VERSION in
2444                                 ([[34]].*)
2445                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2446                                         continue;;
2447                                 esac
2448                                 ;;
2449                         (Wpointer-arith)
2450                                 case $GCC_VERSION in
2451                                 ([[12]].*)
2452                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2453                                         continue;;
2454                                 esac
2455                                 ;;
2456                         esac
2457                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2458                 fi
2459         done
2460         CFLAGS="$cf_save_CFLAGS"
2461 fi
2462 rm -rf conftest*
2463
2464 AC_SUBST(EXTRA_CFLAGS)
2465 ])dnl
2466 dnl ---------------------------------------------------------------------------
2467 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2468 dnl ----------------
2469 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2470 dnl unistd.h or (nonstandard) in getopt.h
2471 AC_DEFUN([CF_GETOPT_HEADER],
2472 [
2473 AC_HAVE_HEADERS(unistd.h getopt.h)
2474 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2475 cf_cv_getopt_header=none
2476 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2477 do
2478 AC_TRY_COMPILE([
2479 #include <$cf_header>],
2480 [int x = optind; char *y = optarg],
2481 [cf_cv_getopt_header=$cf_header
2482  break])
2483 done
2484 ])
2485 if test $cf_cv_getopt_header != none ; then
2486         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2487 fi
2488 if test $cf_cv_getopt_header = getopt.h ; then
2489         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2490 fi
2491 ])dnl
2492 dnl ---------------------------------------------------------------------------
2493 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2494 dnl -----------------
2495 AC_DEFUN([CF_GNATPREP_OPT_T],[
2496 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2497 cf_cv_gnatprep_opt_t=no
2498 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2499 ])
2500 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2501 AC_SUBST(GNATPREP_OPTS)
2502 ])dnl
2503 dnl ---------------------------------------------------------------------------
2504 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
2505 dnl ----------------
2506 AC_DEFUN([CF_GNAT_GENERICS],
2507 [
2508 AC_REQUIRE([CF_GNAT_VERSION])
2509
2510 AC_MSG_CHECKING(if GNAT supports generics)
2511 case $cf_gnat_version in
2512 (3.[[1-9]]*|[[4-9]].*)
2513         cf_gnat_generics=yes
2514         ;;
2515 (*)
2516         cf_gnat_generics=no
2517         ;;
2518 esac
2519 AC_MSG_RESULT($cf_gnat_generics)
2520
2521 if test "$cf_gnat_generics" = yes
2522 then
2523         cf_compile_generics=generics
2524         cf_generic_objects="\${GENOBJS}"
2525 else
2526         cf_compile_generics=
2527         cf_generic_objects=
2528 fi
2529
2530 AC_SUBST(cf_compile_generics)
2531 AC_SUBST(cf_generic_objects)
2532 ])dnl
2533 dnl ---------------------------------------------------------------------------
2534 dnl CF_GNAT_PROJECTS version: 9 updated: 2018/01/14 15:46:09
2535 dnl ----------------
2536 dnl GNAT projects are configured with ".gpr" project files.
2537 dnl GNAT libraries are a further development, using the project feature.
2538 AC_DEFUN([CF_GNAT_PROJECTS],
2539 [
2540 AC_REQUIRE([CF_GNAT_VERSION])
2541 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2542
2543 cf_gnat_libraries=no
2544 cf_gnat_projects=no
2545
2546 if test "$enable_gnat_projects" != no ; then
2547 AC_MSG_CHECKING(if GNAT supports project files)
2548 case $cf_gnat_version in
2549 (3.[[0-9]]*)
2550         ;;
2551 (*)
2552         case $cf_cv_system_name in
2553         (cygwin*|msys*)
2554                 ;;
2555         (*)
2556                 rm -rf conftest* *~conftest*
2557                 if mkdir conftest.src conftest.bin conftest.lib
2558                 then
2559                         cd conftest.src
2560                         rm -rf conftest* *~conftest*
2561                         cat >>library.gpr <<CF_EOF
2562 project Library is
2563   Kind := External ("LIB_KIND");
2564   for Library_Name use "ConfTest";
2565   for Object_Dir use ".";
2566   for Library_ALI_Dir use External("LIBRARY_DIR");
2567   for Library_Version use External ("SONAME");
2568   for Library_Kind use Kind;
2569   for Library_Dir use External("BUILD_DIR");
2570   Source_Dir := External ("SOURCE_DIR");
2571   for Source_Dirs use (Source_Dir);
2572 end Library;
2573 CF_EOF
2574                         cat >>confpackage.ads <<CF_EOF
2575 package ConfPackage is
2576    procedure conftest;
2577 end ConfPackage;
2578 CF_EOF
2579                         cat >>confpackage.adb <<CF_EOF
2580 with Text_IO;
2581 package body ConfPackage is
2582    procedure conftest is
2583    begin
2584       Text_IO.Put ("Hello World");
2585       Text_IO.New_Line;
2586    end conftest;
2587 end ConfPackage;
2588 CF_EOF
2589                         if ( $cf_ada_make $ADAFLAGS \
2590                                         -Plibrary.gpr \
2591                                         -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2592                                         -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2593                                         -XSOURCE_DIR=`pwd` \
2594                                         -XSONAME=libConfTest.so.1 \
2595                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2596                                 cf_gnat_projects=yes
2597                         fi
2598                         cd ..
2599                 fi
2600                 if test -f conftest.lib/confpackage.ali
2601                 then
2602                         cf_gnat_libraries=yes
2603                 fi
2604                 rm -rf conftest* *~conftest*
2605                 ;;
2606         esac
2607         ;;
2608 esac
2609 AC_MSG_RESULT($cf_gnat_projects)
2610 fi # enable_gnat_projects
2611
2612 if test $cf_gnat_projects = yes
2613 then
2614         AC_MSG_CHECKING(if GNAT supports libraries)
2615         AC_MSG_RESULT($cf_gnat_libraries)
2616 fi
2617
2618 if test "$cf_gnat_projects" = yes
2619 then
2620         USE_OLD_MAKERULES="#"
2621         USE_GNAT_PROJECTS=""
2622 else
2623         USE_OLD_MAKERULES=""
2624         USE_GNAT_PROJECTS="#"
2625 fi
2626
2627 if test "$cf_gnat_libraries" = yes
2628 then
2629         USE_GNAT_LIBRARIES=""
2630 else
2631         USE_GNAT_LIBRARIES="#"
2632 fi
2633
2634 AC_SUBST(USE_OLD_MAKERULES)
2635 AC_SUBST(USE_GNAT_PROJECTS)
2636 AC_SUBST(USE_GNAT_LIBRARIES)
2637 ])dnl
2638 dnl ---------------------------------------------------------------------------
2639 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2640 dnl --------------
2641 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2642 dnl is noted that gnat may compile a tasking unit even for configurations which
2643 dnl fail at runtime.
2644 AC_DEFUN([CF_GNAT_SIGINT],[
2645 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2646 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2647
2648 package ConfTest is
2649
2650    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2651    pragma Unreserve_All_Interrupts;
2652    pragma Warnings (On);
2653
2654    protected Process is
2655       procedure Stop;
2656       function Continue return Boolean;
2657       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2658    private
2659       Done : Boolean := False;
2660    end Process;
2661
2662 end ConfTest;],
2663 [package body ConfTest is
2664    protected body Process is
2665       procedure Stop is
2666       begin
2667          Done := True;
2668       end Stop;
2669       function Continue return Boolean is
2670       begin
2671          return not Done;
2672       end Continue;
2673    end Process;
2674 end ConfTest;],
2675         [cf_cv_gnat_sigint=yes],
2676         [cf_cv_gnat_sigint=no])])
2677
2678 if test $cf_cv_gnat_sigint = yes ; then
2679         USE_GNAT_SIGINT=""
2680 else
2681         USE_GNAT_SIGINT="#"
2682 fi
2683 AC_SUBST(USE_GNAT_SIGINT)
2684 ])dnl
2685 dnl ---------------------------------------------------------------------------
2686 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2687 dnl ----------------
2688 dnl Verify that a test program compiles/links with GNAT.
2689 dnl $cf_ada_make is set to the program that compiles/links
2690 dnl $ADAFLAGS may be set to the GNAT flags.
2691 dnl
2692 dnl $1 is the text of the spec
2693 dnl $2 is the text of the body
2694 dnl $3 is the shell command to execute if successful
2695 dnl $4 is the shell command to execute if not successful
2696 AC_DEFUN([CF_GNAT_TRY_LINK],
2697 [
2698 rm -rf conftest* *~conftest*
2699 cat >>conftest.ads <<CF_EOF
2700 $1
2701 CF_EOF
2702 cat >>conftest.adb <<CF_EOF
2703 $2
2704 CF_EOF
2705 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2706 ifelse($3,,      :,[      $3])
2707 ifelse($4,,,[else
2708    $4])
2709 fi
2710 rm -rf conftest* *~conftest*
2711 ])dnl
2712 dnl ---------------------------------------------------------------------------
2713 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2714 dnl ---------------
2715 dnl Verify that a test program compiles and runs with GNAT
2716 dnl $cf_ada_make is set to the program that compiles/links
2717 dnl $ADAFLAGS may be set to the GNAT flags.
2718 dnl
2719 dnl $1 is the text of the spec
2720 dnl $2 is the text of the body
2721 dnl $3 is the shell command to execute if successful
2722 dnl $4 is the shell command to execute if not successful
2723 AC_DEFUN([CF_GNAT_TRY_RUN],
2724 [
2725 rm -rf conftest* *~conftest*
2726 cat >>conftest.ads <<CF_EOF
2727 $1
2728 CF_EOF
2729 cat >>conftest.adb <<CF_EOF
2730 $2
2731 CF_EOF
2732 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2733    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2734 ifelse($3,,      :,[      $3])
2735 ifelse($4,,,[   else
2736       $4])
2737    fi
2738 ifelse($4,,,[else
2739    $4])
2740 fi
2741 rm -rf conftest* *~conftest*
2742 ])dnl
2743 dnl ---------------------------------------------------------------------------
2744 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
2745 dnl ---------------
2746 dnl Verify version of GNAT.
2747 AC_DEFUN([CF_GNAT_VERSION],
2748 [
2749 AC_MSG_CHECKING(for gnat version)
2750 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2751         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2752         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2753 AC_MSG_RESULT($cf_gnat_version)
2754
2755 case $cf_gnat_version in
2756 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
2757         cf_cv_prog_gnat_correct=yes
2758         ;;
2759 (*)
2760         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2761         cf_cv_prog_gnat_correct=no
2762         ;;
2763 esac
2764 ])
2765 dnl ---------------------------------------------------------------------------
2766 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
2767 dnl -------------
2768 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2769 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2770 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2771 dnl since it is interwoven with GNU extensions.
2772 dnl
2773 dnl Well, yes we could work around it...
2774 dnl
2775 dnl Parameters:
2776 dnl     $1 is the nominal value for _XOPEN_SOURCE
2777 AC_DEFUN([CF_GNU_SOURCE],
2778 [
2779 cf_gnu_xopen_source=ifelse($1,,500,$1)
2780
2781 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
2782 AC_TRY_COMPILE([#include <sys/types.h>],[
2783         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
2784                 return 0;
2785         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
2786                 return 0;
2787         #else
2788         #       error not GNU C library
2789         #endif],
2790         [cf_cv_gnu_library=yes],
2791         [cf_cv_gnu_library=no])
2792 ])
2793
2794 if test x$cf_cv_gnu_library = xyes; then
2795
2796         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
2797         # was changed to help a little.  newlib incorporated the change about 4
2798         # years later.
2799         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
2800                 cf_save="$CPPFLAGS"
2801                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
2802                 AC_TRY_COMPILE([#include <sys/types.h>],[
2803                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
2804                                 return 0;
2805                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
2806                                 return 0;
2807                         #else
2808                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
2809                         #endif],
2810                         [cf_cv_gnu_library_219=yes],
2811                         [cf_cv_gnu_library_219=no])
2812                 CPPFLAGS="$cf_save"
2813         ])
2814
2815         if test "x$cf_cv_gnu_library_219" = xyes; then
2816                 cf_save="$CPPFLAGS"
2817                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
2818                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
2819                         AC_TRY_COMPILE([
2820                                 #include <limits.h>
2821                                 #include <sys/types.h>
2822                                 ],[
2823                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
2824                                         return 0;
2825                                 #else
2826                                 #       error GNU C library is too old
2827                                 #endif],
2828                                 [cf_cv_gnu_dftsrc_219=yes],
2829                                 [cf_cv_gnu_dftsrc_219=no])
2830                         ])
2831                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
2832         else
2833                 cf_cv_gnu_dftsrc_219=maybe
2834         fi
2835
2836         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
2837
2838                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2839                 AC_TRY_COMPILE([#include <sys/types.h>],[
2840                         #ifndef _XOPEN_SOURCE
2841                         #error  expected _XOPEN_SOURCE to be defined
2842                         #endif],
2843                         [cf_cv_gnu_source=no],
2844                         [cf_save="$CPPFLAGS"
2845                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
2846                          AC_TRY_COMPILE([#include <sys/types.h>],[
2847                                 #ifdef _XOPEN_SOURCE
2848                                 #error  expected _XOPEN_SOURCE to be undefined
2849                                 #endif],
2850                                 [cf_cv_gnu_source=no],
2851                                 [cf_cv_gnu_source=yes])
2852                         CPPFLAGS="$cf_save"
2853                         ])
2854                 ])
2855
2856                 if test "$cf_cv_gnu_source" = yes
2857                 then
2858                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
2859                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
2860                         AC_TRY_COMPILE([#include <sys/types.h>],[
2861                                 #ifdef _DEFAULT_SOURCE
2862                                 #error  expected _DEFAULT_SOURCE to be undefined
2863                                 #endif],
2864                                 [cf_cv_default_source=no],
2865                                 [cf_cv_default_source=yes])
2866                         ])
2867                         if test "$cf_cv_default_source" = yes
2868                         then
2869                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
2870                         fi
2871                 fi
2872         fi
2873
2874 fi
2875 ])dnl
2876 dnl ---------------------------------------------------------------------------
2877 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
2878 dnl --------------
2879 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2880 dnl problem :-).  If we have the compiler but no library, we'll be able to
2881 dnl configure, but won't be able to build the c++ demo program.
2882 AC_DEFUN([CF_GPP_LIBRARY],
2883 [
2884 cf_cxx_library=unknown
2885 case $cf_cv_system_name in
2886 (os2*)
2887         cf_gpp_libname=gpp
2888         ;;
2889 (*)
2890         cf_gpp_libname=g++
2891         ;;
2892 esac
2893 if test "$GXX" = yes; then
2894         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2895         cf_save="$LIBS"
2896         CF_ADD_LIB($cf_gpp_libname)
2897         AC_TRY_LINK([
2898 #include <$cf_gpp_libname/builtin.h>
2899         ],
2900         [two_arg_error_handler_t foo2 = lib_error_handler],
2901         [cf_cxx_library=yes
2902          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2903          if test "$cf_gpp_libname" = cpp ; then
2904             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2905          else
2906             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2907          fi],
2908         [AC_TRY_LINK([
2909 #include <builtin.h>
2910         ],
2911         [two_arg_error_handler_t foo2 = lib_error_handler],
2912         [cf_cxx_library=yes
2913          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2914          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2915         [cf_cxx_library=no])])
2916         LIBS="$cf_save"
2917         AC_MSG_RESULT($cf_cxx_library)
2918 fi
2919 ])dnl
2920 dnl ---------------------------------------------------------------------------
2921 dnl CF_GXX_VERSION version: 8 updated: 2017/02/11 14:48:57
2922 dnl --------------
2923 dnl Check for version of g++
2924 AC_DEFUN([CF_GXX_VERSION],[
2925 AC_REQUIRE([AC_PROG_CPP])
2926 GXX_VERSION=none
2927 if test "$GXX" = yes; then
2928         AC_MSG_CHECKING(version of ${CXX:-g++})
2929         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2930         if test -z "$GXX_VERSION"
2931         then
2932                 GXX_VERSION=unknown
2933                 GXX=no
2934         fi
2935         AC_MSG_RESULT($GXX_VERSION)
2936 fi
2937 ])dnl
2938 dnl ---------------------------------------------------------------------------
2939 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
2940 dnl ---------------
2941 dnl Check if the compiler supports useful warning options.
2942 dnl
2943 dnl Most of gcc's options apply to g++, except:
2944 dnl     -Wbad-function-cast
2945 dnl     -Wmissing-declarations
2946 dnl     -Wnested-externs
2947 dnl
2948 dnl Omit a few (for now):
2949 dnl     -Winline
2950 dnl
2951 dnl Parameter:
2952 dnl     $1 is an optional list of g++ warning flags that a particular
2953 dnl             application might want to use, e.g., "no-unused" for
2954 dnl             -Wno-unused
2955 dnl Special:
2956 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2957 dnl
2958 AC_DEFUN([CF_GXX_WARNINGS],
2959 [
2960
2961 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2962 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2963
2964 AC_REQUIRE([CF_GXX_VERSION])
2965
2966 AC_LANG_SAVE
2967 AC_LANG_CPLUSPLUS
2968
2969 cat > conftest.$ac_ext <<EOF
2970 #line __oline__ "configure"
2971 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2972 EOF
2973
2974 if test "$INTEL_CPLUSPLUS" = yes
2975 then
2976 # The "-wdXXX" options suppress warnings:
2977 # remark #1419: external declaration in primary source file
2978 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2979 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2980 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2981 # remark #193: zero used for undefined preprocessing identifier
2982 # remark #593: variable "curs_sb_left_arrow" was set but never used
2983 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2984 # remark #869: parameter "tw" was never referenced
2985 # remark #981: operands are evaluated in unspecified order
2986 # warning #269: invalid format string conversion
2987
2988         AC_CHECKING([for $CC warning options])
2989         cf_save_CXXFLAGS="$CXXFLAGS"
2990         EXTRA_CXXFLAGS="-Wall"
2991         for cf_opt in \
2992                 wd1419 \
2993                 wd1682 \
2994                 wd1683 \
2995                 wd1684 \
2996                 wd193 \
2997                 wd279 \
2998                 wd593 \
2999                 wd810 \
3000                 wd869 \
3001                 wd981
3002         do
3003                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
3004                 if AC_TRY_EVAL(ac_compile); then
3005                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3006                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3007                 fi
3008         done
3009         CXXFLAGS="$cf_save_CXXFLAGS"
3010
3011 elif test "$GXX" = yes
3012 then
3013         AC_CHECKING([for $CXX warning options])
3014         cf_save_CXXFLAGS="$CXXFLAGS"
3015         EXTRA_CXXFLAGS="-W -Wall"
3016         cf_gxx_extra_warnings=""
3017         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
3018         case "$GCC_VERSION" in
3019         ([[1-2]].*)
3020                 ;;
3021         (*)
3022                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
3023                 ;;
3024         esac
3025         for cf_opt in \
3026                 Wabi \
3027                 fabi-version=0 \
3028                 Wextra \
3029                 Wignored-qualifiers \
3030                 Wlogical-op \
3031                 Woverloaded-virtual \
3032                 Wsign-promo \
3033                 Wsynth \
3034                 Wold-style-cast \
3035                 Wcast-align \
3036                 Wcast-qual \
3037                 Wpointer-arith \
3038                 Wshadow \
3039                 Wundef $cf_gxx_extra_warnings $1
3040         do
3041                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
3042                 if AC_TRY_EVAL(ac_compile); then
3043                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3044                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3045                 else
3046                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
3047                 fi
3048         done
3049         CXXFLAGS="$cf_save_CXXFLAGS"
3050 fi
3051
3052 rm -rf conftest*
3053 AC_LANG_RESTORE
3054 AC_SUBST(EXTRA_CXXFLAGS)
3055 ])dnl
3056 dnl ---------------------------------------------------------------------------
3057 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
3058 dnl ------------
3059 dnl Look for an instance of the Berkeley hashed database.
3060 dnl
3061 dnl $1 = optional parameter, to specify install-prefix for the database.
3062 AC_DEFUN([CF_HASHED_DB],
3063 [
3064 ifelse([$1],,,[
3065 case $1 in
3066 (yes|*able*)
3067         ;;
3068 (*)
3069         if test -d "$1" ; then
3070                 CF_ADD_INCDIR($1/include)
3071                 CF_ADD_LIBDIR($1/lib)
3072         else
3073                 case "$1" in
3074                 (./*|../*|/*)
3075                         AC_MSG_WARN(no such directory $1)
3076                         ;;
3077                 (*)
3078                         CF_FIND_SUB_INCDIR($1)
3079                         CF_FIND_SUB_LIBDIR($1)
3080                         ;;
3081                 esac
3082         fi
3083 esac
3084 ])
3085 AC_CHECK_HEADER(db.h,[
3086 CF_HASHED_DB_VERSION
3087 if test "$cf_cv_hashed_db_version" = unknown ; then
3088         AC_MSG_ERROR(Cannot determine version of db)
3089 else
3090         CF_HASHED_DB_LIBS
3091         if test "$cf_cv_hashed_db_libs" = unknown ; then
3092                 AC_MSG_ERROR(Cannot determine library for db)
3093         elif test "$cf_cv_hashed_db_libs" != default ; then
3094                 CF_ADD_LIB($cf_cv_hashed_db_libs)
3095         fi
3096 fi
3097 ],[
3098         AC_MSG_ERROR(Cannot find db.h)
3099 ])
3100 ])dnl
3101 dnl ---------------------------------------------------------------------------
3102 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
3103 dnl -----------------
3104 dnl Given that we have the header and version for hashed database, find the
3105 dnl library information.
3106 AC_DEFUN([CF_HASHED_DB_LIBS],
3107 [
3108 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
3109 cf_cv_hashed_db_libs=unknown
3110 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
3111 do
3112         cf_save_libs="$LIBS"
3113         if test -n "$cf_db_libs"; then
3114                 CF_ADD_LIB($cf_db_libs)
3115         fi
3116         CF_MSG_LOG(checking for library "$cf_db_libs")
3117         AC_TRY_LINK([
3118 $ac_includes_default
3119 #include <db.h>
3120 ],[
3121         char *path = "/tmp/foo";
3122 #ifdef DB_VERSION_MAJOR
3123 #if DB_VERSION_MAJOR >= 4
3124         DB *result = 0;
3125         db_create(&result, NULL, 0);
3126         result->open(result,
3127                 NULL,
3128                 path,
3129                 path,
3130                 DB_HASH,
3131                 DB_CREATE,
3132                 0644);
3133 #elif DB_VERSION_MAJOR >= 3
3134         DB *result = 0;
3135         db_create(&result, NULL, 0);
3136         result->open(result,
3137                 path,
3138                 path,
3139                 DB_HASH,
3140                 DB_CREATE,
3141                 0644);
3142 #elif DB_VERSION_MAJOR >= 2
3143         DB *result = 0;
3144         db_open(path,
3145                 DB_HASH,
3146                 DB_CREATE,
3147                 0644,
3148                 (DB_ENV *) 0,
3149                 (DB_INFO *) 0,
3150                 &result);
3151 #endif /* DB_VERSION_MAJOR */
3152 #else
3153         DB *result = dbopen(path,
3154                      2,
3155                      0644,
3156                      DB_HASH,
3157                      0);
3158 #endif
3159         ${cf_cv_main_return:-return}(result != 0)
3160 ],[
3161         if test -n "$cf_db_libs" ; then
3162                 cf_cv_hashed_db_libs=$cf_db_libs
3163         else
3164                 cf_cv_hashed_db_libs=default
3165         fi
3166         LIBS="$cf_save_libs"
3167         break
3168 ])
3169         LIBS="$cf_save_libs"
3170 done
3171 ])
3172 ])dnl
3173 dnl ---------------------------------------------------------------------------
3174 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3175 dnl --------------------
3176 dnl Given that we have the header file for hashed database, find the version
3177 dnl information.
3178 AC_DEFUN([CF_HASHED_DB_VERSION],
3179 [
3180 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3181 cf_cv_hashed_db_version=unknown
3182
3183 for cf_db_version in 1 2 3 4 5 6
3184 do
3185         CF_MSG_LOG(checking for db version $cf_db_version)
3186         AC_TRY_COMPILE([
3187 $ac_includes_default
3188 #include <db.h>
3189
3190 #ifdef DB_VERSION_MAJOR
3191         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3192 #if $cf_db_version == DB_VERSION_MAJOR
3193         /* ok */
3194 #else
3195         make an error
3196 #endif
3197 #else
3198 #if $cf_db_version == 1
3199         /* ok: assuming this is DB 1.8.5 */
3200 #else
3201         make an error
3202 #endif
3203 #endif
3204 ],[DBT *foo = 0],[
3205         cf_cv_hashed_db_version=$cf_db_version
3206         break
3207         ])
3208 done
3209 ])
3210 ])dnl
3211 dnl ---------------------------------------------------------------------------
3212 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
3213 dnl --------------
3214 dnl Construct a search-list of directories for a nonstandard header-file
3215 dnl
3216 dnl Parameters
3217 dnl     $1 = the variable to return as result
3218 dnl     $2 = the package name
3219 AC_DEFUN([CF_HEADER_PATH],
3220 [
3221 $1=
3222
3223 # collect the current set of include-directories from compiler flags
3224 cf_header_path_list=""
3225 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3226         for cf_header_path in $CPPFLAGS $CFLAGS
3227         do
3228                 case $cf_header_path in
3229                 (-I*)
3230                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3231                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3232                         cf_header_path_list="$cf_header_path_list [$]$1"
3233                         ;;
3234                 esac
3235         done
3236 fi
3237
3238 # add the variations for the package we are looking for
3239 CF_SUBDIR_PATH($1,$2,include)
3240
3241 test "$includedir" != NONE && \
3242 test "$includedir" != "/usr/include" && \
3243 test -d "$includedir" && {
3244         test -d $includedir &&    $1="[$]$1 $includedir"
3245         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
3246 }
3247
3248 test "$oldincludedir" != NONE && \
3249 test "$oldincludedir" != "/usr/include" && \
3250 test -d "$oldincludedir" && {
3251         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
3252         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
3253 }
3254
3255 $1="[$]$1 $cf_header_path_list"
3256 ])dnl
3257 dnl ---------------------------------------------------------------------------
3258 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
3259 dnl ---------------
3260 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3261 AC_DEFUN([CF_HELP_MESSAGE],
3262 [AC_DIVERT_HELP([$1])dnl
3263 ])dnl
3264 dnl ---------------------------------------------------------------------------
3265 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3266 dnl ---------------
3267 dnl Construct the list of include-options according to whether we're building
3268 dnl in the source directory or using '--srcdir=DIR' option.
3269 AC_DEFUN([CF_INCLUDE_DIRS],
3270 [
3271 if test "$srcdir" != "."; then
3272         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3273 fi
3274 CPPFLAGS="-I../include $CPPFLAGS"
3275 if test "$srcdir" != "."; then
3276         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3277 fi
3278 CPPFLAGS="-I. $CPPFLAGS"
3279 AC_SUBST(CPPFLAGS)
3280 ])dnl
3281 dnl ---------------------------------------------------------------------------
3282 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
3283 dnl ---------------
3284 dnl prompt for/fill-in useful install-program options
3285 AC_DEFUN([CF_INSTALL_OPTS],
3286 [
3287 CF_INSTALL_OPT_S
3288 CF_INSTALL_OPT_P
3289 CF_INSTALL_OPT_O
3290 ])dnl
3291 dnl ---------------------------------------------------------------------------
3292 dnl CF_INSTALL_OPT_O version: 2 updated: 2015/05/15 19:45:35
3293 dnl ----------------
3294 dnl Almost all "install" programs default to the current user's ownership.
3295 dnl Almost - MINIX is an exception.
3296 AC_DEFUN([CF_INSTALL_OPT_O],
3297 [
3298 AC_MSG_CHECKING(if install needs to be told about ownership)
3299 case `$ac_config_guess` in
3300 (*minix)
3301         with_install_o=yes
3302         ;;
3303 (*)
3304         with_install_o=no
3305         ;;
3306 esac
3307
3308 AC_MSG_RESULT($with_install_o)
3309 if test "x$with_install_o" = xyes
3310 then
3311         INSTALL_OPT_O=`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`
3312 else
3313         INSTALL_OPT_O=
3314 fi
3315
3316 AC_SUBST(INSTALL_OPT_O)
3317 ])dnl
3318 dnl ---------------------------------------------------------------------------
3319 dnl CF_INSTALL_OPT_P version: 1 updated: 2018/08/18 12:19:21
3320 dnl ----------------
3321 dnl Some install-programs accept a "-p" option to preserve file modification
3322 dnl timestamps.  That can be useful as an install option, as well as a way to
3323 dnl avoid the need for ranlib after copying a static archive.
3324 AC_DEFUN([CF_INSTALL_OPT_P],
3325 [
3326 : ${INSTALL:=install}
3327 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
3328         rm -rf conftest*
3329         date >conftest.in
3330         mkdir conftest.out
3331         sleep 3
3332         if $INSTALL -p conftest.in conftest.out 2>/dev/null
3333         then
3334                 if test -f conftest.out/conftest.in
3335                 then
3336                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
3337                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
3338                         if test -s conftest.err
3339                         then
3340                                 cf_cv_install_p=no
3341                         else
3342                                 cf_cv_install_p=yes
3343                         fi
3344                 else
3345                         cf_cv_install_p=no
3346                 fi
3347         else
3348                 cf_cv_install_p=no
3349         fi
3350         rm -rf conftest*
3351 ])
3352 ])dnl
3353 dnl ---------------------------------------------------------------------------
3354 dnl CF_INSTALL_OPT_S version: 2 updated: 2018/08/18 12:19:21
3355 dnl ----------------
3356 dnl By default, we should strip executables which are installed, but leave the
3357 dnl ability to suppress that for unit-testing.
3358 AC_DEFUN([CF_INSTALL_OPT_S],
3359 [
3360 AC_MSG_CHECKING(if you want to install stripped executables)
3361 CF_ARG_DISABLE(stripping,
3362         [  --disable-stripping     do not strip (debug info) installed executables],
3363         [with_stripping=no],
3364         [with_stripping=yes])
3365 AC_MSG_RESULT($with_stripping)
3366
3367 if test "$with_stripping" = yes
3368 then
3369         INSTALL_OPT_S="-s"
3370 else
3371         INSTALL_OPT_S=
3372 fi
3373 AC_SUBST(INSTALL_OPT_S)
3374 ])dnl
3375 dnl ---------------------------------------------------------------------------
3376 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
3377 dnl -----------------
3378 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3379 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3380 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3381 dnl
3382 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3383 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3384 dnl the wrappers for gcc and g++ warnings.
3385 dnl
3386 dnl $1 = GCC (default) or GXX
3387 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3388 dnl $3 = CFLAGS (default) or CXXFLAGS
3389 AC_DEFUN([CF_INTEL_COMPILER],[
3390 AC_REQUIRE([AC_CANONICAL_HOST])
3391 ifelse([$2],,INTEL_COMPILER,[$2])=no
3392
3393 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3394         case $host_os in
3395         (linux*|gnu*)
3396                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3397                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3398                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3399                 AC_TRY_COMPILE([],[
3400 #ifdef __INTEL_COMPILER
3401 #else
3402 make an error
3403 #endif
3404 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3405 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3406 ],[])
3407                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3408                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3409                 ;;
3410         esac
3411 fi
3412 ])dnl
3413 dnl ---------------------------------------------------------------------------
3414 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3415 dnl ----------
3416 dnl Check if we have either a function or macro for 'isascii()'.
3417 AC_DEFUN([CF_ISASCII],
3418 [
3419 AC_MSG_CHECKING(for isascii)
3420 AC_CACHE_VAL(cf_cv_have_isascii,[
3421         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3422         [cf_cv_have_isascii=yes],
3423         [cf_cv_have_isascii=no])
3424 ])dnl
3425 AC_MSG_RESULT($cf_cv_have_isascii)
3426 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3427 ])dnl
3428 dnl ---------------------------------------------------------------------------
3429 dnl CF_LARGEFILE version: 11 updated: 2018/06/20 20:23:13
3430 dnl ------------
3431 dnl Add checks for large file support.
3432 AC_DEFUN([CF_LARGEFILE],[
3433 ifdef([AC_FUNC_FSEEKO],[
3434         AC_SYS_LARGEFILE
3435         if test "$enable_largefile" != no ; then
3436         AC_FUNC_FSEEKO
3437
3438         # Normally we would collect these definitions in the config.h,
3439         # but (like _XOPEN_SOURCE), some environments rely on having these
3440         # defined before any of the system headers are included.  Another
3441         # case comes up with C++, e.g., on AIX the compiler compiles the
3442         # header files by themselves before looking at the body files it is
3443         # told to compile.  For ncurses, those header files do not include
3444         # the config.h
3445         if test "$ac_cv_sys_large_files" != no
3446         then
3447                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
3448         fi
3449         if test "$ac_cv_sys_largefile_source" != no
3450         then
3451                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
3452         fi
3453         if test "$ac_cv_sys_file_offset_bits" != no
3454         then
3455                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
3456         fi
3457
3458         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3459                 AC_TRY_COMPILE([
3460 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
3461 #include <sys/types.h>
3462 #include <dirent.h>
3463                 ],[
3464                 /* if transitional largefile support is setup, this is true */
3465                 extern struct dirent64 * readdir(DIR *);
3466                 struct dirent64 *x = readdir((DIR *)0);
3467                 struct dirent *y = readdir((DIR *)0);
3468                 int z = x - y;
3469                 ],
3470                 [cf_cv_struct_dirent64=yes],
3471                 [cf_cv_struct_dirent64=no])
3472         ])
3473         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3474         fi
3475 ])
3476 ])
3477 dnl ---------------------------------------------------------------------------
3478 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3479 dnl -----------------
3480 dnl Check for compiler/linker flags used to temporarily force usage of static
3481 dnl libraries.  This depends on the compiler and platform.  Use this to help
3482 dnl ensure that the linker picks up a given library based on its position in
3483 dnl the list of linker options and libraries.
3484 AC_DEFUN([CF_LDFLAGS_STATIC],[
3485
3486 if test "$GCC" = yes ; then
3487         case $cf_cv_system_name in
3488         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3489                 LDFLAGS_STATIC=
3490                 LDFLAGS_SHARED=
3491                 ;;
3492         (*)     # normally, except when broken
3493                 LDFLAGS_STATIC=-static
3494                 LDFLAGS_SHARED=-dynamic
3495                 ;;
3496         esac
3497 else
3498         case $cf_cv_system_name in
3499         (aix[[4-7]]*)   # from ld manpage
3500                 LDFLAGS_STATIC=-bstatic
3501                 LDFLAGS_SHARED=-bdynamic
3502                 ;;
3503         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3504                 # We could also use just "archive" and "shared".
3505                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3506                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3507                 ;;
3508         (irix*)         # from ld manpage IRIX64
3509                 LDFLAGS_STATIC=-Bstatic
3510                 LDFLAGS_SHARED=-Bdynamic
3511                 ;;
3512         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3513                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3514                 LDFLAGS_STATIC=-noso
3515                 LDFLAGS_SHARED=-so_archive
3516                 ;;
3517         (solaris2*)
3518                 LDFLAGS_STATIC=-Bstatic
3519                 LDFLAGS_SHARED=-Bdynamic
3520                 ;;
3521         esac
3522 fi
3523
3524 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3525 then
3526         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3527
3528         rm -f libconftest.a
3529         cat >conftest.$ac_ext <<EOF
3530 #line __oline__ "configure"
3531 #include <stdio.h>
3532 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3533 EOF
3534         if AC_TRY_EVAL(ac_compile) ; then
3535                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3536                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3537         fi
3538         rm -f conftest.*
3539
3540         cf_save_LIBS="$LIBS"
3541
3542         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3543         AC_TRY_LINK([
3544 #line __oline__ "configure"
3545 #include <stdio.h>
3546 int cf_ldflags_static(FILE *fp);
3547 ],[
3548         return cf_ldflags_static(stdin);
3549 ],[
3550         # some linkers simply ignore the -dynamic
3551         case x`file conftest$ac_exeext 2>/dev/null` in
3552         (*static*)
3553                 cf_ldflags_static=no
3554                 ;;
3555         (*)
3556                 cf_ldflags_static=yes
3557                 ;;
3558         esac
3559 ],[cf_ldflags_static=no])
3560
3561         rm -f libconftest.*
3562         LIBS="$cf_save_LIBS"
3563
3564         AC_MSG_RESULT($cf_ldflags_static)
3565
3566         if test $cf_ldflags_static != yes
3567         then
3568                 LDFLAGS_STATIC=
3569                 LDFLAGS_SHARED=
3570         fi
3571 else
3572         LDFLAGS_STATIC=
3573         LDFLAGS_SHARED=
3574 fi
3575
3576 AC_SUBST(LDFLAGS_STATIC)
3577 AC_SUBST(LDFLAGS_SHARED)
3578 ])
3579 dnl ---------------------------------------------------------------------------
3580 dnl CF_LD_RPATH_OPT version: 8 updated: 2018/08/18 16:36:35
3581 dnl ---------------
3582 dnl For the given system and compiler, find the compiler flags to pass to the
3583 dnl loader to use the "rpath" feature.
3584 AC_DEFUN([CF_LD_RPATH_OPT],
3585 [
3586 AC_REQUIRE([CF_CHECK_CACHE])
3587
3588 LD_RPATH_OPT=
3589 if test "x$cf_cv_enable_rpath" != xno
3590 then
3591         AC_MSG_CHECKING(for an rpath option)
3592         case $cf_cv_system_name in
3593         (irix*)
3594                 if test "$GCC" = yes; then
3595                         LD_RPATH_OPT="-Wl,-rpath,"
3596                 else
3597                         LD_RPATH_OPT="-rpath "
3598                 fi
3599                 ;;
3600         (linux*|gnu*|k*bsd*-gnu|freebsd*)
3601                 LD_RPATH_OPT="-Wl,-rpath,"
3602                 ;;
3603         (openbsd[[2-9]].*|mirbsd*)
3604                 LD_RPATH_OPT="-Wl,-rpath,"
3605                 ;;
3606         (dragonfly*)
3607                 LD_RPATH_OPT="-rpath "
3608                 ;;
3609         (netbsd*)
3610                 LD_RPATH_OPT="-Wl,-rpath,"
3611                 ;;
3612         (osf*|mls+*)
3613                 LD_RPATH_OPT="-rpath "
3614                 ;;
3615         (solaris2*)
3616                 LD_RPATH_OPT="-R"
3617                 ;;
3618         (*)
3619                 ;;
3620         esac
3621         AC_MSG_RESULT($LD_RPATH_OPT)
3622
3623         case "x$LD_RPATH_OPT" in
3624         (x-R*)
3625                 AC_MSG_CHECKING(if we need a space after rpath option)
3626                 cf_save_LIBS="$LIBS"
3627                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3628                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3629                 LIBS="$cf_save_LIBS"
3630                 AC_MSG_RESULT($cf_rpath_space)
3631                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3632                 ;;
3633         esac
3634 fi
3635 ])dnl
3636 dnl ---------------------------------------------------------------------------
3637 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
3638 dnl ---------------
3639 dnl Construct a search-list of directories for a nonstandard library-file
3640 dnl
3641 dnl Parameters
3642 dnl     $1 = the variable to return as result
3643 dnl     $2 = the package name
3644 AC_DEFUN([CF_LIBRARY_PATH],
3645 [
3646 $1=
3647 cf_library_path_list=""
3648 if test -n "${LDFLAGS}${LIBS}" ; then
3649         for cf_library_path in $LDFLAGS $LIBS
3650         do
3651                 case $cf_library_path in
3652                 (-L*)
3653                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3654                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3655                         cf_library_path_list="$cf_library_path_list [$]$1"
3656                         ;;
3657                 esac
3658         done
3659 fi
3660
3661 CF_SUBDIR_PATH($1,$2,lib)
3662
3663 $1="$cf_library_path_list [$]$1"
3664 ])dnl
3665 dnl ---------------------------------------------------------------------------
3666 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3667 dnl ------------------
3668 AC_DEFUN([CF_LIBTOOL_VERSION],[
3669 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3670 then
3671         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3672 else
3673         cf_cv_libtool_version=
3674 fi
3675 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3676 ])dnl
3677 dnl ---------------------------------------------------------------------------
3678 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
3679 dnl -------------
3680 dnl Compute the library-prefix for the given host system
3681 dnl $1 = variable to set
3682 define([CF_LIB_PREFIX],
3683 [
3684         case $cf_cv_system_name in
3685         (OS/2*|os2*)
3686                 if test "$DFT_LWR_MODEL" = libtool; then
3687                         LIB_PREFIX='lib'
3688                 else
3689                         LIB_PREFIX=''
3690                 fi
3691                 ;;
3692         (*)     LIB_PREFIX='lib'
3693                 ;;
3694         esac
3695 ifelse($1,,,[$1=$LIB_PREFIX])
3696         AC_SUBST(LIB_PREFIX)
3697 ])dnl
3698 dnl ---------------------------------------------------------------------------
3699 dnl CF_LIB_RULES version: 88 updated: 2018/08/18 12:19:21
3700 dnl ------------
3701 dnl Append definitions and rules for the given models to the subdirectory
3702 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3703 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3704 dnl the corresponding makefile to list the models that we'll generate.
3705 dnl
3706 dnl For shared libraries, make a list of symbolic links to construct when
3707 dnl generating each library.  The convention used for Linux is the simplest
3708 dnl one:
3709 dnl     lib<name>.so    ->
3710 dnl     lib<name>.so.<major>    ->
3711 dnl     lib<name>.so.<maj>.<minor>
3712 dnl
3713 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3714 AC_DEFUN([CF_LIB_RULES],
3715 [
3716 cf_prefix=$LIB_PREFIX
3717 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3718
3719 case $cf_cv_shlib_version in
3720 (cygdll|msysdll|mingw)
3721         TINFO_NAME=$TINFO_ARG_SUFFIX
3722         TINFO_SUFFIX=.dll
3723         ;;
3724 esac
3725
3726 if test -n "$TINFO_SUFFIX" ; then
3727         case $TINFO_SUFFIX in
3728         (tw*)
3729                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
3730                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
3731                 ;;
3732         (t*)
3733                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
3734                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
3735                 ;;
3736         (w*)
3737                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
3738                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
3739                 ;;
3740         esac
3741 fi
3742
3743 for cf_dir in $SRC_SUBDIRS
3744 do
3745         if test ! -d $srcdir/$cf_dir ; then
3746                 continue
3747         elif test -f $srcdir/$cf_dir/modules; then
3748
3749                 SHARED_LIB=
3750                 Libs_To_Make=
3751                 cf_awk_program=
3752                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
3753                 then
3754                         cf_awk_program="$cf_awk_program\
3755 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
3756 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
3757 "
3758                 fi
3759
3760                 if test "x$WILDCARD_SYMS" = xno
3761                 then
3762                         cf_awk_program="$cf_awk_program\
3763 /[[     ]]_\\*;/ { skip=1; next; }\
3764 "
3765                 fi
3766
3767                 if test "x$cf_awk_program" != "x"
3768                 then
3769                         cat >>$cf_dir/Makefile <<CF_EOF
3770
3771 # Generated by CF_LIB_RULES
3772 resulting.map: $UNALTERED_SYMS
3773         $AWK 'BEGIN { skip = 1; last=""; } \
3774 $cf_awk_program \
3775 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
3776  skip = 0; last = \[$]\[$]0; } \
3777 END { print last; }' < $UNALTERED_SYMS >\[$]@
3778
3779 distclean::
3780         rm -f resulting.map
3781 CF_EOF
3782                 fi
3783
3784                 for cf_item in $cf_LIST_MODELS
3785                 do
3786                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3787                         cf_libname=$cf_dir
3788                         test "$cf_dir" = c++ && cf_libname=ncurses++
3789                         if test $cf_item = shared ; then
3790                                 if test -n "${LIB_SUFFIX}"
3791                                 then
3792                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3793                                 else
3794                                         cf_shared_suffix="$cf_suffix"
3795                                 fi
3796                                 if test "$cf_cv_do_symlinks" = yes ; then
3797                                         cf_version_name=
3798
3799                                         case "$cf_cv_shlib_version" in
3800                                         (rel)
3801                                                 cf_version_name=REL_VERSION
3802                                                 ;;
3803                                         (abi)
3804                                                 cf_version_name=ABI_VERSION
3805                                                 ;;
3806                                         esac
3807
3808                                         if test -n "$cf_version_name"
3809                                         then
3810                                                 case "$cf_cv_system_name" in
3811                                                 (darwin*)
3812                                                         # "w", etc?
3813                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3814                                                         ;;
3815                                                 (*)
3816                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3817                                                         ;;
3818                                                 esac
3819                                         fi
3820                                         if test -n "${USE_LIB_SUFFIX}"
3821                                         then
3822                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3823                                         else
3824                                                 cf_shared_suffix="$cf_suffix"
3825                                         fi
3826                                 fi
3827                                 # cygwin needs import library, and has unique naming convention
3828                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3829                                 # use 'cyg' prefix for shared lib.
3830                                 case $cf_cv_shlib_version in
3831                                 (cygdll)
3832                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3833                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
3834                                         ;;
3835                                 (msysdll)
3836                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3837                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
3838                                         ;;
3839                                 (mingw)
3840                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3841                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
3842                                         ;;
3843                                 (*)
3844                                         cf_add_lib=
3845                                         ;;
3846                                 esac
3847                                 if test -n "$cf_add_lib"
3848                                 then
3849                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3850                                         continue
3851                                 fi
3852                         fi
3853                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3854                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3855                 done
3856
3857                 if test $cf_dir = ncurses ; then
3858                         cf_subsets="$LIB_SUBSETS"
3859                         cf_r_parts="$cf_subsets"
3860                         cf_liblist="$Libs_To_Make"
3861
3862                         while test -n "$cf_r_parts"
3863                         do
3864                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3865                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3866                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3867                                         cf_add_lib=
3868                                         case $cf_l_parts in
3869                                         (*termlib*)
3870                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3871                                                 ;;
3872                                         (*ticlib*)
3873                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3874                                                 ;;
3875                                         (*)
3876                                                 break
3877                                                 ;;
3878                                         esac
3879                                         if test -n "$cf_add_lib"; then
3880                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
3881                                         fi
3882                                 else
3883                                         break
3884                                 fi
3885                         done
3886                 else
3887                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3888                 fi
3889
3890                 if test $cf_dir = c++; then
3891                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3892                                 cf_list=
3893                                 for cf_item in $Libs_To_Make
3894                                 do
3895                                         case $cf_item in
3896                                         (*.a)
3897                                                 ;;
3898                                         (*)
3899                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3900                                                 ;;
3901                                         esac
3902                                         for cf_test in $cf_list
3903                                         do
3904                                                 if test "$cf_test" = "$cf_item"
3905                                                 then
3906                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3907                                                         cf_item=
3908                                                         break
3909                                                 fi
3910                                         done
3911                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3912                                 done
3913                                 Libs_To_Make="$cf_list"
3914                         fi
3915                 fi
3916
3917                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3918                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3919                         $cf_dir/Makefile >$cf_dir/Makefile.out
3920                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3921
3922                 $AWK -f $srcdir/mk-0th.awk \
3923                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3924                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3925
3926                 for cf_subset in $cf_subsets
3927                 do
3928                         cf_subdirs=
3929                         for cf_item in $cf_LIST_MODELS
3930                         do
3931
3932                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3933                         CF_UPPER(cf_ITEM,$cf_item)
3934
3935                         CXX_MODEL=$cf_ITEM
3936                         if test "$CXX_MODEL" = SHARED; then
3937                                 case $cf_cv_shlib_version in
3938                                 (cygdll|msysdll|mingw)
3939                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3940                                         with_shared_cxx=yes
3941                                         ;;
3942                                 (*)
3943                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3944                                         ;;
3945                                 esac
3946                         fi
3947
3948                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3949                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3950
3951                         # Test for case where we build libtinfo with a different name.
3952                         cf_libname=$cf_dir
3953                         if test $cf_dir = ncurses ; then
3954                                 case $cf_subset in
3955                                 (*base*)
3956                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
3957                                         ;;
3958                                 (*termlib*)
3959                                         cf_libname=$TINFO_LIB_SUFFIX
3960                                         ;;
3961                                 (ticlib*)
3962                                         cf_libname=$TICS_LIB_SUFFIX
3963                                         ;;
3964                                 esac
3965                         elif test $cf_dir = c++ ; then
3966                                 cf_libname=ncurses++$USE_LIB_SUFFIX
3967                         else
3968                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
3969                         fi
3970                         if test -n "${USE_ARG_SUFFIX}" ; then
3971                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
3972                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${USE_LIB_SUFFIX}%%"`
3973                         fi
3974
3975                         # These dependencies really are for development, not
3976                         # builds, but they are useful in porting, too.
3977                         cf_depend="../include/ncurses_cfg.h"
3978                         if test "$srcdir" = "."; then
3979                                 cf_reldir="."
3980                         else
3981                                 cf_reldir="\${srcdir}"
3982                         fi
3983
3984                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3985                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3986                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3987                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3988                         fi
3989
3990                         cf_dir_suffix=
3991                         old_cf_suffix="$cf_suffix"
3992                         if test "$cf_cv_shlib_version_infix" = yes ; then
3993                         if test -n "$USE_LIB_SUFFIX" ; then
3994                                 case $USE_LIB_SUFFIX in
3995                                 (tw*)
3996                                         cf_libname=`echo $cf_libname | sed 's/tw'$EXTRA_SUFFIX'$//'`
3997                                         cf_suffix=`echo $cf_suffix | sed 's/^tw'$EXTRA_SUFFIX'//'`
3998                                         cf_dir_suffix=tw$EXTRA_SUFFIX
3999                                         ;;
4000                                 (t*)
4001                                         cf_libname=`echo $cf_libname | sed 's/t'$EXTRA_SUFFIX'$//'`
4002                                         cf_suffix=`echo $cf_suffix | sed 's/^t'$EXTRA_SUFFIX'//'`
4003                                         cf_dir_suffix=t$EXTRA_SUFFIX
4004                                         ;;
4005                                 (w*)
4006                                         cf_libname=`echo $cf_libname | sed 's/w'$EXTRA_SUFFIX'$//'`
4007                                         cf_suffix=`echo $cf_suffix | sed 's/^w'$EXTRA_SUFFIX'//'`
4008                                         cf_dir_suffix=w$EXTRA_SUFFIX
4009                                         ;;
4010                                 (*)
4011                                         cf_libname=`echo $cf_libname | sed 's/'$EXTRA_SUFFIX'$//'`
4012                                         cf_suffix=`echo $cf_suffix | sed 's/^'$EXTRA_SUFFIX'//'`
4013                                         cf_dir_suffix=$EXTRA_SUFFIX
4014                                         ;;
4015                                 esac
4016                         fi
4017                         fi
4018
4019                         $AWK -f $srcdir/mk-1st.awk \
4020                                 name=${cf_libname}${cf_dir_suffix} \
4021                                 traces=$LIB_TRACING \
4022                                 MODEL=$cf_ITEM \
4023                                 CXX_MODEL=$CXX_MODEL \
4024                                 model=$cf_subdir \
4025                                 prefix=$cf_prefix \
4026                                 suffix=$cf_suffix \
4027                                 subset=$cf_subset \
4028                                 driver=$cf_cv_term_driver \
4029                                 SymLink="$LN_S" \
4030                                 TermlibRoot=$TINFO_NAME \
4031                                 TermlibSuffix=$TINFO_SUFFIX \
4032                                 ShlibVer=$cf_cv_shlib_version \
4033                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
4034                                 ReLink=${cf_cv_do_relink:-no} \
4035                                 ReRanlib=${cf_cv_do_reranlib:-yes} \
4036                                 DoLinks=$cf_cv_do_symlinks \
4037                                 rmSoLocs=$cf_cv_rm_so_locs \
4038                                 ldconfig="$LDCONFIG" \
4039                                 overwrite=$WITH_OVERWRITE \
4040                                 depend="$cf_depend" \
4041                                 host="$host" \
4042                                 libtool_version="$LIBTOOL_VERSION" \
4043                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4044
4045                         cf_suffix="$old_cf_suffix"
4046
4047                         for cf_subdir2 in $cf_subdirs lib
4048                         do
4049                                 test $cf_subdir = $cf_subdir2 && break
4050                         done
4051                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
4052                         $AWK -f $srcdir/mk-2nd.awk \
4053                                 name=$cf_dir \
4054                                 traces=$LIB_TRACING \
4055                                 MODEL=$cf_ITEM \
4056                                 model=$cf_subdir \
4057                                 subset=$cf_subset \
4058                                 srcdir=$srcdir \
4059                                 echo=$WITH_ECHO \
4060                                 crenames=$cf_cv_prog_CC_c_o \
4061                                 cxxrenames=$cf_cv_prog_CXX_c_o \
4062                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4063                         cf_subdirs="$cf_subdirs $cf_subdir"
4064                         done
4065                 done
4066         fi
4067
4068         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
4069 done
4070
4071 for cf_dir in $SRC_SUBDIRS
4072 do
4073         if test ! -d $srcdir/$cf_dir ; then
4074                 continue
4075         fi
4076
4077         if test -f $cf_dir/Makefile ; then
4078                 case "$cf_dir" in
4079                 (Ada95)
4080                         echo 'libs \' >> Makefile
4081                         echo 'install.libs \' >> Makefile
4082                         echo 'uninstall.libs ::' >> Makefile
4083                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
4084                         ;;
4085                 esac
4086         fi
4087
4088         if test -f $srcdir/$cf_dir/modules; then
4089                 echo >> Makefile
4090                 if test -f $srcdir/$cf_dir/headers; then
4091 cat >> Makefile <<CF_EOF
4092 install.includes \\
4093 uninstall.includes \\
4094 CF_EOF
4095                 fi
4096 if test "$cf_dir" != "c++" ; then
4097 echo 'lint \' >> Makefile
4098 fi
4099 cat >> Makefile <<CF_EOF
4100 libs \\
4101 lintlib \\
4102 install.libs \\
4103 uninstall.libs \\
4104 install.$cf_dir \\
4105 uninstall.$cf_dir ::
4106         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
4107 CF_EOF
4108         elif test -f $srcdir/$cf_dir/headers; then
4109 cat >> Makefile <<CF_EOF
4110
4111 libs \\
4112 install.libs \\
4113 uninstall.libs \\
4114 install.includes \\
4115 uninstall.includes ::
4116         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
4117 CF_EOF
4118 fi
4119 done
4120
4121 if test "x$cf_with_db_install" = xyes; then
4122 cat >> Makefile <<CF_EOF
4123
4124 install.libs uninstall.libs \\
4125 install.data uninstall.data ::
4126 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
4127 CF_EOF
4128 else
4129 cat >> Makefile <<CF_EOF
4130
4131 install.libs uninstall.libs ::
4132         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
4133 CF_EOF
4134 fi
4135
4136 if test "x$cf_with_manpages" = xyes; then
4137 cat >> Makefile <<CF_EOF
4138
4139 install.man \\
4140 uninstall.man ::
4141         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
4142 CF_EOF
4143 fi
4144
4145 cat >> Makefile <<CF_EOF
4146
4147 distclean ::
4148         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
4149         rm -f headers.sh headers.sed mk_shared_lib.sh
4150         rm -f edit_man.* man_alias.*
4151         rm -rf \${DIRS_TO_MAKE}
4152 CF_EOF
4153
4154 # Special case: tack's manpage lives in its own directory.
4155 if test "x$cf_with_manpages" = xyes; then
4156 if test "x$cf_with_tack" = "xyes"; then
4157 cat >> Makefile <<CF_EOF
4158
4159 install.man \\
4160 uninstall.man ::
4161         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
4162 CF_EOF
4163 fi
4164 fi
4165
4166 dnl If we're installing into a subdirectory of /usr/include, etc., we should
4167 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
4168 dnl anything, and will make it more standardized.  It's awkward to decide this
4169 dnl at configuration because of quoting, so we'll simply make all headers
4170 dnl installed via a script that can do the right thing.
4171
4172 rm -f headers.sed headers.sh
4173
4174 dnl ( generating this script makes the makefiles a little tidier :-)
4175 echo creating headers.sh
4176 cat >headers.sh <<CF_EOF
4177 #! $SHELL
4178 # This shell script is generated by the 'configure' script.  It is invoked in a
4179 # subdirectory of the build tree.  It generates a sed-script in the parent
4180 # directory that is used to adjust includes for header files that reside in a
4181 # subdirectory of /usr/include, etc.
4182 PRG=""
4183 while test \[$]# != 3
4184 do
4185 PRG="\$PRG \[$]1"; shift
4186 done
4187 DST=\[$]1
4188 REF=\[$]2
4189 SRC=\[$]3
4190 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
4191 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
4192 echo installing \$SRC in \$DST
4193 CF_EOF
4194
4195 if test $WITH_CURSES_H = yes; then
4196         cat >>headers.sh <<CF_EOF
4197 case \$DST in
4198 (/*/include/*)
4199         END=\`basename \$DST\`
4200         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
4201         do
4202                 NAME=\`basename \$i\`
4203                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4204         done
4205         ;;
4206 (*)
4207         echo "" >> \$TMPSED
4208         ;;
4209 esac
4210 CF_EOF
4211
4212 else
4213         cat >>headers.sh <<CF_EOF
4214 case \$DST in
4215 (/*/include/*)
4216         END=\`basename \$DST\`
4217         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
4218         do
4219                 NAME=\`basename \$i\`
4220                 if test "\$NAME" = "curses.h"
4221                 then
4222                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4223                         NAME=ncurses.h
4224                 fi
4225                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4226         done
4227         ;;
4228 (*)
4229         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4230         ;;
4231 esac
4232 CF_EOF
4233 fi
4234 cat >>headers.sh <<CF_EOF
4235 rm -f \$TMPSRC
4236 sed -f \$TMPSED \$SRC > \$TMPSRC
4237 NAME=\`basename \$SRC\`
4238 CF_EOF
4239 if test $WITH_CURSES_H != yes; then
4240         cat >>headers.sh <<CF_EOF
4241 test "\$NAME" = "curses.h" && NAME=ncurses.h
4242 CF_EOF
4243 fi
4244 cat >>headers.sh <<CF_EOF
4245 # Just in case someone gzip'd manpages, remove the conflicting copy.
4246 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
4247
4248 eval \$PRG \$TMPSRC \$DST/\$NAME
4249 rm -f \$TMPSRC \$TMPSED
4250 CF_EOF
4251
4252 chmod 0755 headers.sh
4253
4254 for cf_dir in $SRC_SUBDIRS
4255 do
4256         if test ! -d $srcdir/$cf_dir ; then
4257                 continue
4258         fi
4259
4260         if test -f $srcdir/$cf_dir/headers; then
4261                 $AWK -f $srcdir/mk-hdr.awk \
4262                         subset="$LIB_SUBSETS" \
4263                         compat="$WITH_CURSES_H" \
4264                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
4265         fi
4266
4267         if test -f $srcdir/$cf_dir/modules; then
4268                 if test "$cf_dir" != "c++" ; then
4269                         cat >>$cf_dir/Makefile <<"CF_EOF"
4270 depend : ${AUTO_SRC}
4271         makedepend -- ${CPPFLAGS} -- ${C_SRC}
4272
4273 # DO NOT DELETE THIS LINE -- make depend depends on it.
4274 CF_EOF
4275                 fi
4276         fi
4277 done
4278 AC_SUBST(Libs_To_Make)
4279 ])dnl
4280 dnl ---------------------------------------------------------------------------
4281 dnl CF_LIB_SONAME version: 6 updated: 2017/01/21 11:06:25
4282 dnl -------------
4283 dnl Find the and soname for the given shared library.  Set the cache variable
4284 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
4285 dnl variable to "unknown".
4286 dnl
4287 dnl $1 = headers
4288 dnl $2 = code
4289 dnl $3 = library name
4290 AC_DEFUN([CF_LIB_SONAME],
4291 [
4292 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
4293
4294 cf_cv_$3_soname=unknown
4295 if test "$cross_compiling" != yes ; then
4296 cat >conftest.$ac_ext <<CF_EOF
4297 $1
4298 int main(void)
4299 {
4300 $2
4301         ${cf_cv_main_return:-return}(0);
4302 }
4303 CF_EOF
4304 cf_save_LIBS="$LIBS"
4305         CF_ADD_LIB($3)
4306         if AC_TRY_EVAL(ac_compile) ; then
4307                 if AC_TRY_EVAL(ac_link) ; then
4308                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
4309                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
4310                 fi
4311         fi
4312 rm -rf conftest*
4313 LIBS="$cf_save_LIBS"
4314 fi