ncurses 5.6 - patch 20070106
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2005,2006 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: configure.in,v 1.384 2006/12/23 23:33:52 tom Exp $
32 dnl Process this file with autoconf to produce a configure script.
33 dnl
34 dnl See http://invisible-island.net/autoconf/ for additional information.
35 dnl
36 dnl ---------------------------------------------------------------------------
37 AC_PREREQ(2.13.20020210)
38 AC_REVISION($Revision: 1.384 $)
39 AC_INIT(ncurses/base/lib_initscr.c)
40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
41
42 CF_TOP_BUILDDIR
43 CF_SUBST_NCURSES_VERSION
44
45 CF_WITH_REL_VERSION(NCURSES)
46 CF_WITH_ABI_VERSION
47
48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
49 AC_ARG_WITH(system-type,
50 [  --with-system-type=XXX  test: override derived host system-type],
51 [AC_MSG_WARN(overriding system type to $withval)
52  cf_cv_system_name=$withval])
53
54 ###     Save the given $CFLAGS to allow user-override.
55 cf_user_CFLAGS="$CFLAGS"
56
57 ###     Default install-location
58 CF_CFG_DEFAULTS
59
60 ###     Checks for programs.
61 AC_PROG_CC
62 CF_GCC_VERSION
63
64 AC_PROG_CPP
65 AC_PROG_GCC_TRADITIONAL
66 CF_PROG_CC_C_O(CC)
67 AC_ISC_POSIX
68 CF_ANSI_CC_REQD
69 CF_PROG_EXT
70 CF_PROG_LDCONFIG
71
72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
73 dnl                             configure script by not letting us test if C++
74 dnl                             is present, making this option necessary.
75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
76 AC_ARG_WITH(cxx,
77         [  --without-cxx           do not adjust ncurses bool to match C++],
78         [cf_with_cxx=$withval],
79         [cf_with_cxx=yes])
80 AC_MSG_RESULT($cf_with_cxx)
81 if test "X$cf_with_cxx" = Xno ; then
82         CXX=""
83         GXX=""
84 else
85         # with autoconf 2.13, we can change the error to a warning:
86         pushdef([AC_MSG_ERROR],
87                 [AC_MSG_RESULT(no)
88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
90         AC_PROG_CXX
91         popdef([AC_MSG_ERROR])dnl
92         # autoconf 2.5x removed the error - by hardcoding it to g++.
93         if test "$CXX" = "g++" ; then
94                 AC_PATH_PROG(CXX,g++)
95         fi
96         if test "$CXX" = "g++" ; then
97                 AC_MSG_WARN(ignoring hardcoded g++)
98                 cf_with_cxx=no; CXX=""; GXX="";
99         fi
100 fi
101
102 CF_GXX_VERSION
103 case $GXX_VERSION in
104 1*|2.[[0-6]]*)
105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
106         # cf_cxx_library=no
107         AC_MSG_WARN(templates do not work)
108         ;;
109 esac
110
111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
112 AC_ARG_WITH(cxx-binding,
113         [  --without-cxx-binding   do not build C++ binding and demo],
114         [cf_with_cxx_binding=$withval],
115         [cf_with_cxx_binding=$cf_with_cxx])
116 AC_MSG_RESULT($cf_with_cxx_binding)
117
118 AC_MSG_CHECKING(if you want to build with Ada95)
119 AC_ARG_WITH(ada,
120         [  --without-ada           suppress check for Ada95, don't build demo],
121         [cf_with_ada=$withval],
122         [cf_with_ada=yes])
123 AC_MSG_RESULT($cf_with_ada)
124
125 AC_MSG_CHECKING(if you want to build programs such as tic)
126 AC_ARG_WITH(progs,
127         [  --without-progs         suppress build with programs (e.g., tic)],
128         [cf_with_progs=$withval],
129         [cf_with_progs=yes])
130 AC_MSG_RESULT($cf_with_progs)
131
132 AC_MSG_CHECKING(if you wish to install curses.h)
133 AC_ARG_WITH(curses-h,
134         [  --without-curses-h      install curses.h as ncurses.h only],
135         [with_curses_h=$withval],
136         [with_curses_h=yes])
137 AC_MSG_RESULT($with_curses_h)
138
139 modules_to_build="ncurses"
140 if test "X$cf_with_progs" != Xno ; then
141 modules_to_build="$modules_to_build progs tack"
142 fi
143 modules_to_build="$modules_to_build panel menu form"
144
145 AC_ARG_PROGRAM
146
147 CF_PROG_AWK
148 CF_PROG_EGREP
149 CF_PROG_INSTALL
150 CF_PROG_LINT
151 AC_PROG_LN_S
152
153 AC_PROG_MAKE_SET
154 CF_MAKE_TAGS
155 CF_MAKEFLAGS
156
157 AC_SYS_LONG_FILE_NAMES
158 CF_MIXEDCASE_FILENAMES
159
160 dnl These are standard among *NIX systems, but not when cross-compiling
161 AC_CHECK_TOOL(RANLIB, ranlib, ':')
162 AC_CHECK_TOOL(LD, ld, ld)
163 AC_CHECK_TOOL(AR, ar, ar)
164 CF_SUBST(archiver options,AR_OPTS,rv)
165
166 dnl Special option for use by system-builders: the install-prefix is used to
167 dnl adjust the location into which the actual install is done, so that an
168 dnl archive can be built without modifying the host system's configuration.
169 AC_MSG_CHECKING(if you have specified an install-prefix)
170 AC_ARG_WITH(install-prefix,
171         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
172         [case "$withval" in #(vi
173         yes|no) #(vi
174                 ;;
175         *)      DESTDIR="$withval"
176                 ;;
177         esac])
178 AC_MSG_RESULT($DESTDIR)
179 AC_SUBST(DESTDIR)
180
181 ###############################################################################
182 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
183 # If we're cross-compiling, allow the user to override the tools and their
184 # options.  The configure script is oriented toward identifying the host
185 # compiler, etc., but we need a build compiler to generate parts of the source.
186 CF_BUILD_CC
187
188 ###############################################################################
189 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
190
191 ### Options to allow the user to specify the set of libraries which are used.
192 ### Use "--without-normal --with-shared" to allow the default model to be
193 ### shared, for example.
194 cf_list_models=""
195 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
196
197 CF_WITH_LIBTOOL
198 if test "$with_libtool" != "no" ; then
199
200 cf_list_models="$cf_list_models libtool"
201
202 else
203
204 AC_MSG_CHECKING(if you want to build shared libraries)
205 AC_ARG_WITH(shared,
206         [  --with-shared           generate shared-libraries],
207         [with_shared=$withval],
208         [with_shared=no])
209 AC_MSG_RESULT($with_shared)
210 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
211
212 AC_MSG_CHECKING(if you want to build static libraries)
213 AC_ARG_WITH(normal,
214         [  --with-normal           generate normal-libraries (default)],
215         [with_normal=$withval],
216         [with_normal=yes])
217 AC_MSG_RESULT($with_normal)
218 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
219
220 AC_MSG_CHECKING(if you want to build debug libraries)
221 AC_ARG_WITH(debug,
222         [  --with-debug            generate debug-libraries (default)],
223         [with_debug=$withval],
224         [with_debug=yes])
225 AC_MSG_RESULT($with_debug)
226 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
227
228 AC_MSG_CHECKING(if you want to build profiling libraries)
229 AC_ARG_WITH(profile,
230         [  --with-profile          generate profile-libraries],
231         [with_profile=$withval],
232         [with_profile=no])
233 AC_MSG_RESULT($with_profile)
234 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
235
236 fi
237
238 ###############################################################################
239
240 AC_MSG_CHECKING(for specified models)
241 test -z "$cf_list_models" && cf_list_models=normal
242 dnl If we use libtool to generate libraries, then it must be the only
243 dnl specified model.
244 test "$with_libtool" != "no" && cf_list_models=libtool
245 AC_MSG_RESULT($cf_list_models)
246
247 ### Use the first model as the default, and save its suffix for use in building
248 ### up test-applications.
249 AC_MSG_CHECKING(for default model)
250 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
251 AC_MSG_RESULT($DFT_LWR_MODEL)
252
253 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
254
255 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
256 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
257
258 TINFO_NAME=tinfo
259 AC_SUBST(TINFO_NAME)
260
261 LIB_NAME=ncurses
262 AC_SUBST(LIB_NAME)
263
264 LIB_DIR=../lib
265 LIB_2ND=../../lib
266
267 CF_LIB_PREFIX(cf_prefix)
268 LIB_PREFIX=$cf_prefix
269 AC_SUBST(LIB_PREFIX)
270
271 LIB_SUFFIX=
272 AC_SUBST(LIB_SUFFIX)
273
274 ###############################################################################
275
276 AC_MSG_CHECKING(if you want to build a separate terminfo library)
277 AC_ARG_WITH(termlib,
278         [  --with-termlib          generate separate terminfo library],
279         [with_termlib=$withval],
280         [with_termlib=no])
281 AC_MSG_RESULT($with_termlib)
282
283 ### Checks for special libraries, must be done up-front.
284 SHLIB_LIST=""
285 CF_WITH_GPM
286 if test "$with_gpm" != no ; then
287         AC_MSG_CHECKING(if you want to load GPM dynamically)
288         AC_ARG_WITH(dlsym,
289                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
290                 [with_dlsym=$withval],
291                 [with_dlsym=yes])
292         AC_MSG_RESULT($with_dlsym)
293         if test "$with_dlsym" = yes ; then
294                 CF_FUNC_DLSYM
295                 if test "$with_gpm" != yes ; then
296                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
297                         cf_cv_gpm_soname="$with_gpm"
298                 else
299                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
300                 fi
301                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
302                 SHLIB_LIST="-ldl $SHLIB_LIST"
303         else
304                 SHLIB_LIST="-lgpm $SHLIB_LIST"
305         fi
306         AC_DEFINE(HAVE_LIBGPM)
307         AC_CHECK_LIB(gpm,Gpm_Wgetch,[
308                 AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
309         ])
310 fi
311
312 CF_WITH_SYSMOUSE
313
314 dnl Not all ports of gcc support the -g option
315
316 if test X"$CC_G_OPT" = X"" ; then
317         CC_G_OPT='-g'
318         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
319 fi
320 AC_SUBST(CC_G_OPT)
321
322 if test X"$CXX_G_OPT" = X"" ; then
323         CXX_G_OPT='-g'
324         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
325 fi
326 AC_SUBST(CXX_G_OPT)
327
328 AC_MSG_CHECKING(for default loader flags)
329 case $DFT_LWR_MODEL in
330 libtool) LD_MODEL=''   ;;
331 normal)  LD_MODEL=''   ;;
332 debug)   LD_MODEL=$CC_G_OPT ;;
333 profile) LD_MODEL='-pg';;
334 shared)  LD_MODEL=''   ;;
335 esac
336 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
337 AC_MSG_RESULT($LD_MODEL)
338
339 AC_MSG_CHECKING(if rpath option should be used)
340 AC_ARG_ENABLE(rpath,
341 [  --enable-rpath          use rpath option when generating shared libraries],
342 [cf_cv_ld_rpath=$enableval],
343 [cf_cv_ld_rpath=no])
344 AC_MSG_RESULT($cf_cv_ld_rpath)
345
346 CF_SHARED_OPTS
347 if test "$CC_SHARED_OPTS" = "unknown"; then
348         for model in $cf_list_models; do
349                 if test "$model" = "shared"; then
350                         AC_ERROR(Shared libraries are not supported in this version)
351                 fi
352         done
353 fi
354
355 ###############################################################################
356 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
357
358 ###     use option --disable-overwrite to leave out the link to -lcurses
359 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
360 AC_ARG_ENABLE(overwrite,
361         [  --disable-overwrite     leave out the link to -lcurses],
362         [with_overwrite=$enableval],
363         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
364 AC_MSG_RESULT($with_overwrite)
365
366 AC_MSG_CHECKING(if external terminfo-database is used)
367 AC_ARG_ENABLE(database,
368         [  --disable-database      do not use terminfo, only fallbacks/termcap],
369         [use_database=$enableval],
370         [use_database=yes])
371 AC_MSG_RESULT($use_database)
372
373 case $host_os in #(vi
374 os2*) #(vi
375         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
376         ;;
377 *) #(vi
378         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
379         ;;
380 esac
381 AC_SUBST(TERMINFO_SRC)
382
383 CF_PATHSEP
384 if test "$use_database" != no ; then
385         AC_DEFINE(USE_DATABASE)
386
387         AC_MSG_CHECKING(which terminfo source-file will be installed)
388         AC_ARG_ENABLE(database,
389                 [  --with-database=XXX     specify terminfo source to install],
390                 [TERMINFO_SRC=$withval])
391         AC_MSG_RESULT($TERMINFO_SRC)
392
393         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
394         AC_ARG_WITH(hashed-db,
395                 [  --with-hashed-db        specify hashed-database library],,
396                 [with_hashed_db=no])
397         AC_MSG_RESULT($with_hashed_db)
398 fi
399
400 AC_MSG_CHECKING(for list of fallback descriptions)
401 AC_ARG_WITH(fallbacks,
402         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
403         [with_fallback=$withval],
404         [with_fallback=])
405 AC_MSG_RESULT($with_fallback)
406 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
407 AC_SUBST(FALLBACK_LIST)
408
409 AC_MSG_CHECKING(if you want modern xterm or antique)
410 AC_ARG_WITH(xterm-new,
411         [  --without-xterm-new     specify if xterm terminfo should be old version],
412         [with_xterm_new=$withval],
413         [with_xterm_new=yes])
414 case $with_xterm_new in
415 no)     with_xterm_new=xterm-old;;
416 *)      with_xterm_new=xterm-new;;
417 esac
418 AC_MSG_RESULT($with_xterm_new)
419 WHICH_XTERM=$with_xterm_new
420 AC_SUBST(WHICH_XTERM)
421
422 MAKE_TERMINFO=
423 if test "$use_database" = no ; then
424         TERMINFO="${datadir}/terminfo"
425         MAKE_TERMINFO="#"
426 else
427
428 AC_MSG_CHECKING(for list of terminfo directories)
429 CF_WITH_PATHLIST(terminfo-dirs,
430         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
431         TERMINFO_DIRS,
432         DATADIR/terminfo,
433         ${datadir}/terminfo)
434 AC_MSG_RESULT($TERMINFO_DIRS)
435 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
436
437 AC_MSG_CHECKING(for default terminfo directory)
438 CF_WITH_PATH(default-terminfo-dir,
439         [  --with-default-terminfo-dir=DIR default terminfo directory],
440         TERMINFO,
441         DATADIR/terminfo,
442         ${datadir}/terminfo)
443 AC_MSG_RESULT($TERMINFO)
444 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
445
446 fi
447
448 AC_SUBST(TERMINFO)
449 AC_SUBST(MAKE_TERMINFO)
450
451 ###     use option --disable-big-core to make tic run on small machines
452 ###     We need 4Mb, check if we can allocate 50% more than that.
453 AC_MSG_CHECKING(if big-core option selected)
454 AC_ARG_ENABLE(big-core,
455         [  --disable-big-core      assume machine has little memory],
456         [with_big_core=$enableval],
457         [AC_TRY_RUN([
458 #include <stdlib.h>
459 #include <string.h>
460 int main() {
461         unsigned long n = 6000000L;
462         char *s = malloc(n);
463         if (s != 0)
464                 s[0] = s[n-1] = 0;
465         ${cf_cv_main_return:-return}(s == 0);
466 }],
467         [with_big_core=yes],
468         [with_big_core=no],
469         [with_big_core=no])])
470 AC_MSG_RESULT($with_big_core)
471 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
472
473 ###     use option --enable-termcap to compile in the termcap fallback support
474 AC_MSG_CHECKING(if you want termcap-fallback support)
475 AC_ARG_ENABLE(termcap,
476         [  --enable-termcap        compile in termcap fallback support],
477         [with_termcap=$enableval],
478         [with_termcap=no])
479 AC_MSG_RESULT($with_termcap)
480
481 if test "$with_termcap" != "yes" ; then
482         if test "$use_database" = no ; then
483                 if test -z "$with_fallback" ; then
484                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
485                 fi
486         fi
487         AC_DEFINE(PURE_TERMINFO)
488 else
489
490 AC_DEFINE(USE_TERMCAP)
491 AC_MSG_CHECKING(for list of termcap files)
492 CF_WITH_PATHLIST(termpath,
493         [  --with-termpath=XXX     specify list of termcap files],
494         TERMPATH,
495         /etc/termcap:/usr/share/misc/termcap)
496 AC_MSG_RESULT($TERMPATH)
497 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
498
499 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
500 AC_MSG_CHECKING(if fast termcap-loader is needed)
501 AC_ARG_ENABLE(getcap,
502         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
503         [with_getcap=$enableval],
504         [with_getcap=no])
505 AC_MSG_RESULT($with_getcap)
506 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
507
508 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
509 AC_ARG_ENABLE(getcap-cache,
510         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
511         [with_getcap_cache=$enableval],
512         [with_getcap_cache=no])
513 AC_MSG_RESULT($with_getcap_cache)
514 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
515
516 fi
517
518 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
519 AC_MSG_CHECKING(if ~/.terminfo is wanted)
520 AC_ARG_ENABLE(home-terminfo,
521         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
522         [with_home_terminfo=$enableval],
523         [with_home_terminfo=yes])
524 AC_MSG_RESULT($with_home_terminfo)
525 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
526
527 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
528 AC_ARG_ENABLE(root-environ,
529         [  --disable-root-environ  restrict environment when running as root],
530         [with_root_environ=$enableval],
531         [with_root_environ=yes])
532 AC_MSG_RESULT($with_root_environ)
533 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
534
535 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
536 ###   to reduce storage requirements for the terminfo database.
537 CF_LINK_FUNCS
538
539 with_links=no
540 with_symlinks=no
541
542 # soft links (symbolic links) are useful for some systems where hard links do
543 # not work, or to make it simpler to copy terminfo trees around.
544 if test "$ac_cv_func_symlink" = yes ; then
545     AC_MSG_CHECKING(if tic should use symbolic links)
546     AC_ARG_ENABLE(symlinks,
547         [  --enable-symlinks       make tic use symbolic links not hard links],
548         [with_symlinks=$enableval],
549         [with_symlinks=no])
550     AC_MSG_RESULT($with_symlinks)
551 fi
552
553 # If we have hard links and did not choose to use soft links instead, there is
554 # no reason to make this choice optional - use the hard links.
555 if test "$with_symlinks" = no ; then
556     AC_MSG_CHECKING(if tic should use hard links)
557     if test "$ac_cv_func_link" = yes ; then
558         with_links=yes
559     else
560         with_links=no
561     fi
562     AC_MSG_RESULT($with_links)
563 fi
564
565 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
566 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
567
568 ###   use option --enable-broken-linker to force on use of broken-linker support
569 AC_MSG_CHECKING(if you want broken-linker support code)
570 AC_ARG_ENABLE(broken_linker,
571         [  --enable-broken_linker  compile with broken-linker support code],
572         [with_broken_linker=$enableval],
573         [with_broken_linker=${BROKEN_LINKER-no}])
574 AC_MSG_RESULT($with_broken_linker)
575
576 BROKEN_LINKER=0
577 if test "$with_broken_linker" = yes ; then
578         AC_DEFINE(BROKEN_LINKER)
579         BROKEN_LINKER=1
580 elif test "$DFT_LWR_MODEL" = shared ; then
581         case $cf_cv_system_name in #(vi
582         cygwin*)
583                 AC_DEFINE(BROKEN_LINKER)
584                 BROKEN_LINKER=1
585                 CF_VERBOSE(cygwin linker is broken anyway)
586                 ;;
587         esac
588 fi
589 AC_SUBST(BROKEN_LINKER)
590
591 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
592 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
593 AC_ARG_ENABLE(bsdpad,
594         [  --enable-bsdpad         recognize BSD-style prefix padding],
595         [with_bsdpad=$enableval],
596         [with_bsdpad=no])
597 AC_MSG_RESULT($with_bsdpad)
598 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
599
600 ###   use option --enable-widec to turn on use of wide-character support
601 NCURSES_CH_T=chtype
602 NCURSES_LIBUTF8=0
603
604 NEED_WCHAR_H=0
605 NCURSES_MBSTATE_T=0
606 NCURSES_WCHAR_T=0
607 NCURSES_WINT_T=0
608
609 # Check to define _XOPEN_SOURCE "automatically"
610 CF_XOPEN_SOURCE
611
612 # Work around breakage on OS X
613 CF_SIGWINCH
614
615 # Checks for CODESET support.
616 AM_LANGINFO_CODESET
617
618 # use these variables to work around a defect in gcc's fixincludes.
619 NCURSES_OK_WCHAR_T=
620 NCURSES_OK_WINT_T=
621
622 AC_MSG_CHECKING(if you want wide-character code)
623 AC_ARG_ENABLE(widec,
624         [  --enable-widec          compile with wide-char/UTF-8 code],
625         [with_widec=$enableval],
626         [with_widec=no])
627 AC_MSG_RESULT($with_widec)
628 if test "$with_widec" = yes ; then
629         LIB_SUFFIX="w${LIB_SUFFIX}"
630         AC_DEFINE(USE_WIDEC_SUPPORT)
631         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
632         # with_overwrite=no
633         NCURSES_CH_T=cchar_t
634         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc)
635         if test "$ac_cv_func_putwc" != yes ; then
636                 CF_LIBUTF8
637                 if test "$cf_cv_libutf8" = yes ; then
638                         NCURSES_LIBUTF8=1
639                 fi
640         fi
641         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
642         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
643         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
644
645         if test "$NCURSES_MBSTATE_T" != 0; then
646                 AC_DEFINE(NEED_MBSTATE_T_DEF)
647         fi
648 fi
649 AC_SUBST(NCURSES_CH_T)
650 AC_SUBST(NCURSES_LIBUTF8)
651
652 AC_SUBST(NEED_WCHAR_H)
653 AC_SUBST(NCURSES_MBSTATE_T)
654 AC_SUBST(NCURSES_WCHAR_T)
655 AC_SUBST(NCURSES_WINT_T)
656
657 AC_SUBST(NCURSES_OK_WCHAR_T)
658 AC_SUBST(NCURSES_OK_WINT_T)
659
660 ###   use option --disable-lp64 to allow long chtype
661 case $cf_cv_abi_version in
662 [[345]]*)
663         default_with_lp64=no
664         ;;
665 *)
666         default_with_lp64=yes
667         ;;
668 esac
669
670 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
671 AC_ARG_ENABLE(lp64,
672         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
673         [with_lp64=$enableval],
674         [with_lp64=$default_with_lp64])
675 AC_MSG_RESULT($with_lp64)
676
677 if test "$with_lp64" = yes ; then
678         cf_cv_enable_lp64=1
679 else
680         cf_cv_enable_lp64=0
681 fi
682 AC_SUBST(cf_cv_enable_lp64)
683
684 CF_LARGEFILE
685
686 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open 
687 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
688 AC_ARG_ENABLE(tparm-varargs,
689         [  --disable-tparm-varargs compile tparm() without varargs interface],
690         [with_tparm_varargs=$enableval],
691         [with_tparm_varargs=yes])
692 AC_MSG_RESULT($with_tparm_varargs)
693 NCURSES_TPARM_VARARGS=0
694 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
695 AC_SUBST(NCURSES_TPARM_VARARGS)
696
697 ###   use option --with-bool to override bool's type
698 AC_MSG_CHECKING(for type of bool)
699 AC_ARG_WITH(bool,
700         [  --with-bool=TYPE        override fallback type of bool variable],
701         [NCURSES_BOOL="$withval"],
702         [NCURSES_BOOL=auto])
703 AC_MSG_RESULT($NCURSES_BOOL)
704 AC_SUBST(NCURSES_BOOL)
705
706 AC_MSG_CHECKING(for alternate terminal capabilities file)
707 AC_ARG_WITH(caps,
708         [  --with-caps=alt         compile with alternate Caps file],
709         [TERMINFO_CAPS=Caps.$withval],
710         [TERMINFO_CAPS=Caps])
711 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
712 AC_MSG_RESULT($TERMINFO_CAPS)
713 AC_SUBST(TERMINFO_CAPS)
714
715 ###   use option --with-chtype to override chtype's type
716 AC_MSG_CHECKING(for type of chtype)
717 AC_ARG_WITH(chtype,
718         [  --with-chtype=TYPE      override type of chtype],
719         [NCURSES_CHTYPE="$withval"],
720         [NCURSES_CHTYPE=auto])
721 AC_MSG_RESULT($NCURSES_CHTYPE)
722
723 ###   use option --with-ospeed to override ospeed's type
724 AC_MSG_CHECKING(for type of ospeed)
725 AC_ARG_WITH(ospeed,
726         [  --with-ospeed=TYPE      override type of ospeed variable],
727         [NCURSES_OSPEED="$withval"],
728         [NCURSES_OSPEED=short])
729 AC_MSG_RESULT($NCURSES_OSPEED)
730 AC_SUBST(NCURSES_OSPEED)
731
732 ###   use option --with-mmask-t to override mmask_t's type
733 AC_MSG_CHECKING(for type of mmask_t)
734 AC_ARG_WITH(mmask-t,
735         [  --with-mmask-t=TYPE     override type of mmask_t],
736         [NCURSES_MMASK_T="$withval"],
737         [NCURSES_MMASK_T=auto])
738 AC_MSG_RESULT($NCURSES_MMASK_T)
739
740 ### Enable compiling-in rcs id's
741 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
742 AC_ARG_WITH(rcs-ids,
743         [  --with-rcs-ids          compile-in RCS identifiers],
744         [with_rcs_ids=$withval],
745         [with_rcs_ids=no])
746 AC_MSG_RESULT($with_rcs_ids)
747 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
748
749 ###############################################################################
750 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tic toe tput ])
751
752 ###############################################################################
753 CF_HELP_MESSAGE(Extensions:)
754
755 ### Note that some functions (such as const) are normally disabled anyway.
756 AC_MSG_CHECKING(if you want to build with function extensions)
757 AC_ARG_ENABLE(ext-funcs,
758         [  --disable-ext-funcs     disable function-extensions],
759         [with_ext_funcs=$enableval],
760         [with_ext_funcs=yes])
761 AC_MSG_RESULT($with_ext_funcs)
762 if test "$with_ext_funcs" = yes ; then
763         NCURSES_EXT_FUNCS=1
764         AC_DEFINE(HAVE_CURSES_VERSION)
765         AC_DEFINE(HAVE_HAS_KEY)
766         AC_DEFINE(HAVE_RESIZETERM)
767         AC_DEFINE(HAVE_RESIZE_TERM)
768         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
769         AC_DEFINE(HAVE_WRESIZE)
770         AC_DEFINE(NCURSES_EXT_FUNCS)
771 else
772         NCURSES_EXT_FUNCS=0
773 fi
774 AC_SUBST(NCURSES_EXT_FUNCS)
775
776 ###   use option --enable-const to turn on use of const beyond that in XSI.
777 AC_MSG_CHECKING(for extended use of const keyword)
778 AC_ARG_ENABLE(const,
779         [  --enable-const          compile with extra/non-standard const],
780         [with_ext_const=$enableval],
781         [with_ext_const=no])
782 AC_MSG_RESULT($with_ext_const)
783 NCURSES_CONST='/*nothing*/'
784 if test "$with_ext_const" = yes ; then
785         NCURSES_CONST=const
786 fi
787 AC_SUBST(NCURSES_CONST)
788
789 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
790 AC_ARG_ENABLE(no-padding,
791         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
792         [with_no_padding=$enableval],
793         [with_no_padding=$with_ext_funcs])
794 AC_MSG_RESULT($with_no_padding)
795 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
796
797 AC_CHECK_SIZEOF([signed char], 0)
798 if test "$ac_cv_sizeof_signed_char" = 1 ; then
799         NCURSES_SBOOL="signed char"
800 else
801         NCURSES_SBOOL="char"
802 fi
803 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
804 AC_ARG_ENABLE(signed-char,
805         [  --enable-signed-char    compile with SIGWINCH handler],
806         [with_signed_char=$enableval],
807         [with_signed_char=no])
808 AC_MSG_RESULT($with_signed_char)
809 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
810 AC_SUBST(NCURSES_SBOOL)
811
812 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
813 AC_MSG_CHECKING(if you want SIGWINCH handler)
814 AC_ARG_ENABLE(sigwinch,
815         [  --enable-sigwinch       compile with SIGWINCH handler],
816         [with_sigwinch=$enableval],
817         [with_sigwinch=$with_ext_funcs])
818 AC_MSG_RESULT($with_sigwinch)
819 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
820
821 ###   use option --enable-tcap-names to allow user to define new capabilities
822 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
823 AC_ARG_ENABLE(tcap-names,
824         [  --enable-tcap-names     compile with user-definable terminal capabilities],
825         [with_tcap_names=$enableval],
826         [with_tcap_names=$with_ext_funcs])
827 AC_MSG_RESULT($with_tcap_names)
828 NCURSES_XNAMES=0
829 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
830 AC_SUBST(NCURSES_XNAMES)
831
832 ###############################################################################
833 # These options are relatively safe to experiment with.
834 CF_HELP_MESSAGE(Development Code:)
835 AC_MSG_CHECKING(if you want all development code)
836 AC_ARG_WITH(develop,
837         [  --without-develop       disable development options],
838         [with_develop=$withval],
839         [with_develop=no])
840 AC_MSG_RESULT($with_develop)
841
842 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
843 AC_MSG_CHECKING(if you want hard-tabs code)
844 AC_ARG_ENABLE(hard-tabs,
845         [  --enable-hard-tabs      compile with hard-tabs code],,
846         [enable_hard_tabs=$with_develop])
847 AC_MSG_RESULT($enable_hard_tabs)
848 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
849
850 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
851 AC_MSG_CHECKING(if you want limited support for xmc)
852 AC_ARG_ENABLE(xmc-glitch,
853         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
854         [enable_xmc_glitch=$with_develop])
855 AC_MSG_RESULT($enable_xmc_glitch)
856 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
857
858 ###############################################################################
859 # These are just experimental, probably should not be in a package:
860 CF_HELP_MESSAGE(Experimental Code:)
861
862 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
863 AC_ARG_ENABLE(assumed-color,
864         [  --disable-assumed-color do not assume anything about default-colors],
865         [with_assumed_color=$enableval],
866         [with_assumed_color=yes])
867 AC_MSG_RESULT($with_assumed_color)
868 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
869
870 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
871 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
872 AC_ARG_ENABLE(hashmap,
873         [  --disable-hashmap       compile without hashmap scrolling-optimization],
874         [with_hashmap=$enableval],
875         [with_hashmap=yes])
876 AC_MSG_RESULT($with_hashmap)
877 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
878
879 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
880 AC_MSG_CHECKING(if you want colorfgbg code)
881 AC_ARG_ENABLE(colorfgbg,
882         [  --enable-colorfgbg      compile with $COLORFGBG code],
883         [with_colorfgbg=$enableval],
884         [with_colorfgbg=no])
885 AC_MSG_RESULT($with_colorfgbg)
886 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
887
888 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
889 AC_MSG_CHECKING(if you want to use experimental extended colors)
890 AC_ARG_ENABLE(ext-colors,
891         [  --enable-ext-colors     compile for experimental 256-color support],
892         [with_ext_colors=$enableval],
893         [with_ext_colors=no])
894 AC_MSG_RESULT($with_ext_colors)
895 NCURSES_EXT_COLORS=0
896 if test "$with_ext_colors" = yes ; then
897         if test "$with_widec" != yes ; then
898                 AC_MSG_WARN(This option applies only to wide-character library)
899         else
900                 # cannot be ABI 5 since it changes sizeof(cchar_t)
901                 CF_NCURSES_ABI_6
902         fi
903         NCURSES_EXT_COLORS=1
904         AC_DEFINE(NCURSES_EXT_COLORS)
905 fi
906 AC_SUBST(NCURSES_EXT_COLORS)
907
908 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
909 AC_MSG_CHECKING(if you want to use experimental extended mouse encoding)
910 AC_ARG_ENABLE(ext-mouse,
911         [  --enable-ext-mouse      compile for experimental mouse-encoding],
912         [with_ext_mouse=$enableval],
913         [with_ext_mouse=no])
914 AC_MSG_RESULT($with_ext_mouse)
915 NCURSES_MOUSE_VERSION=1
916 if test "$with_ext_mouse" = yes ; then
917         NCURSES_MOUSE_VERSION=2
918         CF_NCURSES_ABI_6
919 fi
920 AC_SUBST(NCURSES_MOUSE_VERSION)
921
922 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
923 AC_ARG_ENABLE(safe-sprintf,
924         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
925         [with_safe_sprintf=$enableval],
926         [with_safe_sprintf=no])
927 AC_MSG_RESULT($with_safe_sprintf)
928 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
929
930 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
931 # when hashmap is used scroll hints are useless
932 if test "$with_hashmap" = no ; then
933 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
934 AC_ARG_ENABLE(scroll-hints,
935         [  --disable-scroll-hints  compile without scroll-hints code],
936         [with_scroll_hints=$enableval],
937         [with_scroll_hints=yes])
938 AC_MSG_RESULT($with_scroll_hints)
939 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
940 fi
941
942 AC_MSG_CHECKING(if you want experimental wgetch-events code)
943 AC_ARG_ENABLE(wgetch-events,
944         [  --enable-wgetch-events  compile with experimental wgetch-events code],
945         [with_wgetch_events=$enableval],
946         [with_wgetch_events=no])
947 AC_MSG_RESULT($with_wgetch_events)
948 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
949
950 ###############################################################################
951 CF_HELP_MESSAGE(Testing/development Options:)
952
953 ###     use option --disable-echo to suppress full display compiling commands
954 AC_MSG_CHECKING(if you want to display full commands during build)
955 AC_ARG_ENABLE(echo,
956         [  --enable-echo           build: display "compiling" commands (default)],
957         [with_echo=$enableval],
958         [with_echo=yes])
959 if test "$with_echo" = yes; then
960         ECHO_LINK=
961 else
962         ECHO_LINK='@ echo linking $@ ... ;'
963         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
964 fi
965 AC_MSG_RESULT($with_echo)
966 AC_SUBST(ECHO_LINK)
967
968 ###     use option --enable-warnings to turn on all gcc warnings
969 AC_MSG_CHECKING(if you want to see compiler warnings)
970 AC_ARG_ENABLE(warnings,
971         [  --enable-warnings       build: turn on GCC compiler warnings],
972         [with_warnings=$enableval])
973 AC_MSG_RESULT($with_warnings)
974
975 if test -n "$with_warnings"; then
976         ADAFLAGS="$ADAFLAGS -gnatg"
977         CF_GCC_WARNINGS
978         if test "$cf_with_cxx" = yes ; then
979                 CF_GXX_WARNINGS(Wno-unused)
980         fi
981 fi
982 CF_GCC_ATTRIBUTES
983
984 ###     use option --enable-assertions to turn on generation of assertion code
985 AC_MSG_CHECKING(if you want to enable runtime assertions)
986 AC_ARG_ENABLE(assertions,
987         [  --enable-assertions     test: turn on generation of assertion code],
988         [with_assertions=$enableval],
989         [with_assertions=no])
990 AC_MSG_RESULT($with_assertions)
991 if test -n "$GCC"
992 then
993         if test "$with_assertions" = no
994         then
995                 AC_DEFINE(NDEBUG)
996                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
997         else
998                 ADAFLAGS="$ADAFLAGS -gnata"
999         fi
1000 fi
1001
1002 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1003 CF_DISABLE_LEAKS
1004 AC_DEFINE(HAVE_NC_ALLOC_H)
1005
1006 ###     use option --enable-expanded to generate certain macros as functions
1007 AC_ARG_ENABLE(expanded,
1008         [  --enable-expanded       test: generate functions for certain macros],
1009         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1010
1011 ###     use option --disable-macros to suppress macros in favor of functions
1012 AC_ARG_ENABLE(macros,
1013         [  --disable-macros        test: use functions rather than macros],
1014         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1015
1016 # Normally we only add trace() to the debug-library.  Allow this to be
1017 # extended to all models of the ncurses library:
1018 cf_all_traces=no
1019 case "$CFLAGS $CPPFLAGS" in
1020 *-DTRACE*)
1021         cf_all_traces=yes
1022         ;;
1023 esac
1024
1025 AC_MSG_CHECKING(whether to add trace feature to all models)
1026 AC_ARG_WITH(trace,
1027 [  --with-trace            test: add trace() function to all models of ncurses],
1028 [cf_with_trace=$withval],
1029 [cf_with_trace=$cf_all_traces])
1030 AC_MSG_RESULT($cf_with_trace)
1031
1032 if test "$cf_with_trace" = yes ; then
1033         LIB_TRACING=all
1034         ADA_TRACE=TRUE
1035         CF_ADD_CFLAGS(-DTRACE)
1036 else
1037         LIB_TRACING=DEBUG
1038         ADA_TRACE=FALSE
1039 fi
1040
1041 AC_SUBST(ADA_TRACE)
1042
1043 ###     Checks for libraries.
1044 AC_CHECK_FUNC(gettimeofday,
1045         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1046
1047 AC_CHECK_LIB(bsd, gettimeofday,
1048         AC_DEFINE(HAVE_GETTIMEOFDAY)
1049         LIBS="$LIBS -lbsd")])dnl CLIX: bzero, select, gettimeofday
1050
1051 CF_MATH_LIB(MATH_LIB,sin(x))
1052 AC_SUBST(MATH_LIB)
1053
1054 ###     Checks for header files.
1055 AC_STDC_HEADERS
1056 AC_HEADER_DIRENT
1057 AC_HEADER_TIME
1058 CF_REGEX
1059
1060 dnl These are some other potentially nonportable headers.
1061 AC_CHECK_HEADERS( \
1062 fcntl.h \
1063 getopt.h \
1064 limits.h \
1065 locale.h \
1066 poll.h \
1067 sys/bsdtypes.h \
1068 sys/ioctl.h \
1069 sys/param.h \
1070 sys/poll.h \
1071 sys/select.h \
1072 sys/time.h \
1073 sys/times.h \
1074 ttyent.h \
1075 unistd.h \
1076 wctype.h \
1077 )
1078
1079 # check for ISC (this may also define _POSIX_SOURCE)
1080 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1081 if test "$ISC" = yes ; then
1082         AC_CHECK_LIB(cposix,main)
1083         AC_CHECK_LIB(inet,bzero,LIBS="$LIBS -linet")dnl also 'select()'
1084 fi
1085
1086 CF_SYS_TIME_SELECT
1087
1088 ###     checks for compiler characteristics
1089 AC_LANG_C
1090 AC_C_CONST
1091 AC_C_INLINE
1092
1093 NCURSES_INLINE=
1094 if test "$ac_cv_c_inline" != no ; then
1095         AC_DEFINE(CC_HAS_INLINE_FUNCS)
1096         NCURSES_INLINE=inline
1097 fi
1098 AC_SUBST(NCURSES_INLINE)
1099
1100 if test $NCURSES_CHTYPE = auto ; then
1101         CF_TYPEOF_CHTYPE
1102 else
1103         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1104 fi
1105 AC_SUBST(cf_cv_typeof_chtype)
1106
1107 CF_UNSIGNED_LITERALS
1108 cf_cv_1UL="1"
1109 test "$cf_cv_unsigned_literals" = yes && cf_cv_1UL="${cf_cv_1UL}U"
1110 test "$cf_cv_typeof_chtype"    = long && cf_cv_1UL="${cf_cv_1UL}L"
1111 AC_SUBST(cf_cv_1UL)
1112
1113 if test $NCURSES_MMASK_T = auto ; then
1114         cf_cv_typeof_mmask_t=long
1115 else
1116         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1117 fi
1118 AC_SUBST(cf_cv_typeof_mmask_t)
1119
1120 ###     Checks for external-data
1121 CF_ERRNO
1122 CF_LINK_DATAONLY
1123
1124 ###     Checks for library functions.
1125 AC_CHECK_FUNCS( \
1126 getcwd \
1127 getegid \
1128 geteuid \
1129 getttynam \
1130 issetugid \
1131 poll \
1132 remove \
1133 select \
1134 setbuf \
1135 setbuffer \
1136 setvbuf \
1137 sigaction \
1138 sigvec \
1139 strdup \
1140 strstr \
1141 tcgetpgrp \
1142 times \
1143 vsnprintf \
1144 )
1145 if test "$with_getcap" = "yes" ; then
1146         CF_CGETENT
1147 fi
1148
1149 CF_ISASCII
1150 CF_STRUCT_SIGACTION
1151 CF_FUNC_NANOSLEEP
1152 CF_FUNC_TERMIOS
1153 CF_FUNC_VSSCANF
1154 CF_MKSTEMP
1155
1156 # setup for prototype of fallback for vsscanf()
1157 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1158
1159 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1160 if test "$cross_compiling" = yes ; then
1161         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1162 else
1163         AC_FUNC_SETVBUF_REVERSED
1164 fi
1165 AC_TYPE_SIGNAL
1166 CF_TYPE_SIGACTION
1167 CF_SIZECHANGE
1168 CF_FUNC_MEMMOVE
1169 CF_FUNC_POLL
1170
1171 if test "$with_hashed_db" != no ; then
1172         AC_DEFINE(USE_HASHED_DB)
1173         CF_HASHED_DB
1174 fi
1175
1176 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1177 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1178         CF_STRIP_G_OPT(CFLAGS)
1179         CF_STRIP_G_OPT(CXXFLAGS)
1180 fi
1181
1182 # Just in case, check if the C compiler has a bool type.
1183 CF_BOOL_DECL(cf_cv_cc_bool_type)
1184
1185 # Check for C++ compiler characteristics (and ensure that it's there!)
1186 if test -n "$CXX" ; then
1187         AC_LANG_CPLUSPLUS
1188         CF_STDCPP_LIBRARY
1189         CF_PROG_CC_C_O(CXX)
1190
1191         case $GXX_VERSION in
1192         1*|2.[0-6]*)
1193                 cf_cxx_library=yes
1194                 ;;
1195         *-2.7*|2.7*)
1196                 CF_GPP_LIBRARY
1197                 ;;
1198         *)
1199                 cf_cxx_library=no
1200                 ;;
1201         esac
1202
1203         AC_CHECK_HEADERS(typeinfo)
1204
1205         CF_BOOL_DECL
1206         CF_BOOL_SIZE
1207         CF_ETIP_DEFINES
1208         CF_CPP_PARAM_INIT
1209         CF_CPP_STATIC_CAST
1210         CF_CPP_VSCAN_FUNC
1211
1212         CXX_AR='$(AR)'
1213         CXX_AR_OPTS='$(AR_OPTS)'
1214         case $cf_cv_system_name in #(vi
1215         irix*) #(vi
1216             if test "$GXX" != yes ; then
1217                 CXX_AR='$(CXX)'
1218                 CXX_AR_OPTS='-ar -o'
1219             fi
1220             ;;
1221         sco3.2v5*) #(vi
1222             CXXLDFLAGS="-u main"
1223             ;;
1224         solaris2*)
1225             if test "$GXX" != yes ; then
1226                 CXX_AR='$(CXX)'
1227                 CXX_AR_OPTS='-xar -o'
1228             fi
1229             ;;
1230         esac
1231         AC_SUBST(CXXLDFLAGS)
1232         AC_SUBST(CXX_AR)
1233         AC_SUBST(CXX_AR_OPTS)
1234 else
1235         cf_cxx_library=no
1236         cf_cv_builtin_bool=1
1237
1238         # Just because we are not configuring against C++ right now does not
1239         # mean that a user will not want to use C++.  Some distributors disable
1240         # the C++ portion of this configuration as a shortcut (or just to avoid
1241         # compiling the demo in the c++ directory).  So we need a reasonable
1242         # default for the 'bool' type.
1243         #
1244         # Caveat: since the storage of the bool type is not standardized, it
1245         # may change.
1246
1247         if test "$NCURSES_BOOL" != auto ; then
1248                 cf_cv_type_of_bool=$NCURSES_BOOL
1249                 cf_cv_header_stdbool_h=0
1250         else
1251                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1252                         CF_BOOL_SIZE
1253                 else
1254                         AC_MSG_CHECKING(for fallback type of bool)
1255                         case "$host_cpu" in #(vi
1256                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1257                         *)      cf_cv_type_of_bool=int  ;;
1258                         esac
1259                         AC_MSG_RESULT($cf_cv_type_of_bool)
1260                 fi
1261         fi
1262 fi
1263 AC_SUBST(CXXLIBS)
1264
1265 # If the C compiler did not declare bool, and we did not determine that the C++
1266 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1267 # ncurses library use the same type as C++ bool.  Note that this allows one to
1268 # specify the type of bool in a configure-script option and postpone
1269 # integration with the C++ compiler provided that the types are compatible.
1270 USE_CXX_BOOL=1
1271 if test $cf_cv_cc_bool_type = 1
1272 then
1273         # oops: C has a bool.  Unlikely, but C++ could differ.
1274         USE_CXX_BOOL=0
1275 elif test $cf_cv_builtin_bool = 0
1276 then
1277         # C++ has no bool
1278         USE_CXX_BOOL=0
1279 else
1280         # this is the normal case
1281         USE_CXX_BOOL='defined(__cplusplus)'
1282 fi
1283 AC_SUBST(USE_CXX_BOOL)
1284
1285 CF_HELP_MESSAGE(Ada95 Binding Options:)
1286
1287 dnl Check for availability of GNU Ada Translator (GNAT).
1288 dnl At the moment we support no other Ada95 compiler.
1289 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1290 if test "$cf_with_ada" != "no" ; then
1291 cf_ada_make=gnatmake
1292 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
1293 if test "$ac_cv_prog_gnat_exists" = no; then
1294    cf_ada_make=
1295 else
1296    CF_GNAT_VERSION
1297    AC_CHECK_PROG(M4_exists, m4, yes, no)
1298    if test "$ac_cv_prog_M4_exists" = no; then
1299       cf_cv_prog_gnat_correct=no
1300       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
1301    fi
1302    if test "$cf_cv_prog_gnat_correct" = yes; then
1303       AC_MSG_CHECKING(if GNAT works)
1304       CF_GNAT_TRY_RUN([procedure conftest;],
1305 [with Text_IO;
1306 with GNAT.OS_Lib;
1307 procedure conftest is
1308 begin
1309    Text_IO.Put ("Hello World");
1310    Text_IO.New_Line;
1311    GNAT.OS_Lib.OS_Exit (0);
1312 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
1313       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
1314    fi
1315 fi
1316 if test "$cf_cv_prog_gnat_correct" = yes; then
1317    ADAFLAGS="-O3 -gnatpn $ADAFLAGS"
1318
1319    AC_MSG_CHECKING(if GNAT pragma Unreferenced works)
1320    CF_GNAT_TRY_LINK([procedure conftest;],
1321 [with Text_IO;
1322 with GNAT.OS_Lib;
1323 procedure conftest is
1324    test : Integer;
1325    pragma Unreferenced (test);
1326 begin
1327    test := 1;
1328    Text_IO.Put ("Hello World");
1329    Text_IO.New_Line;
1330    GNAT.OS_Lib.OS_Exit (0);
1331 end conftest;],[cf_cv_pragma_unreferenced=yes],[cf_cv_pragma_unreferenced=no])
1332    AC_MSG_RESULT($cf_cv_pragma_unreferenced)
1333
1334    # if the pragma is supported, use it (needed in the Trace code).
1335    if test $cf_cv_pragma_unreferenced = yes ; then
1336       PRAGMA_UNREF=TRUE
1337    else
1338       PRAGMA_UNREF=FALSE
1339    fi
1340
1341    AC_ARG_WITH(ada-compiler,
1342         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
1343         [cf_ada_compiler=$withval],
1344         [cf_ada_compiler=gnatmake])
1345
1346    cf_ada_package=terminal_interface
1347
1348    AC_SUBST(cf_ada_make)
1349    AC_SUBST(cf_ada_compiler)
1350    AC_SUBST(cf_ada_package)
1351    AC_SUBST(ADAFLAGS)
1352    AC_SUBST(cf_compile_generics)
1353    AC_SUBST(cf_generic_objects)
1354    AC_SUBST(PRAGMA_UNREF)
1355
1356    CF_WITH_PATH(ada-include,
1357        [  --with-ada-include=DIR  Ada includes are in DIR],
1358        ADA_INCLUDE,
1359        PREFIX/lib/ada/adainclude,
1360        [$]prefix/lib/ada/adainclude)
1361    AC_SUBST(ADA_INCLUDE)
1362
1363    CF_WITH_PATH(ada-objects,
1364        [  --with-ada-objects=DIR  Ada objects are in DIR],
1365        ADA_OBJECTS,
1366        PREFIX/lib/ada/adalib,
1367        [$]prefix/lib/ada/adalib)
1368    AC_SUBST(ADA_OBJECTS)
1369
1370 fi
1371 fi
1372 fi
1373
1374 ### Construct the library-subsets, if any, from this set of keywords:
1375 ### none, base, ext_funcs, ext_tinfo, termlib, widechar (see CF_LIB_RULES).
1376 AC_MSG_CHECKING(for library subsets)
1377 if test "$with_termlib" != no ; then
1378         LIB_SUBSETS="termlib"
1379         test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1380         test "$cf_with_progs"  = yes && LIB_SUBSETS="${LIB_SUBSETS}+programs"
1381         LIB_SUBSETS="${LIB_SUBSETS} "
1382 else
1383         LIB_SUBSETS="termlib+"
1384         test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}ext_tinfo+"
1385         test "$cf_with_progs"  = yes && LIB_SUBSETS="${LIB_SUBSETS}programs+"
1386 fi
1387 LIB_SUBSETS="${LIB_SUBSETS}base"
1388 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1389 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1390 AC_MSG_RESULT($LIB_SUBSETS)
1391
1392 ### Construct the list of include-directories to be generated
1393 CF_INCLUDE_DIRS
1394 CF_ADA_INCLUDE_DIRS
1395
1396 ### Build up pieces for makefile rules
1397 AC_MSG_CHECKING(default library suffix)
1398 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1399 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1400 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1401
1402 AC_MSG_CHECKING(default library-dependency suffix)
1403 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_DEP_SUFFIX)dnl
1404 if test $DFT_LWR_MODEL = shared ; then
1405         case $cf_cv_system_name in #(vi
1406         cygwin*)
1407                 DFT_DEP_SUFFIX=".dll.a"
1408                 ;;
1409         esac
1410 fi
1411 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1412 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1413
1414 AC_MSG_CHECKING(default object directory)
1415 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1416 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1417 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1418
1419 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1420 if test "$cf_with_cxx" = yes ; then
1421 AC_MSG_CHECKING(c++ library-dependency suffix)
1422 if test "$with_libtool" != "no"; then
1423         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1424 else
1425         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX)dnl we normally make a static library
1426 fi
1427 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1428 AC_SUBST(CXX_LIB_SUFFIX)
1429 fi
1430
1431 ### Set up low-level terminfo dependencies for makefiles.
1432 TINFO_LIST="$SHLIB_LIST"
1433 if test "$with_termlib" != no ; then
1434
1435         if test "$with_termlib" != yes ; then
1436                 TINFO_NAME=$with_termlib
1437                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1438                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1439                 TINFO_LIB_SUFFIX="${with_termlib}"
1440         else
1441                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1442                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1443                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1444         fi
1445
1446         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1447         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1448         if test "$DFT_LWR_MODEL" = "libtool"; then
1449                 TEST_ARGS="${TEST_DEPS}"
1450                 TEST_ARG2="${TEST_DEP2}"
1451                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1452         else
1453                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1454                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1455                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1456                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1457         fi
1458 else
1459         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1460 fi
1461 AC_SUBST(TINFO_ARG_SUFFIX)
1462 AC_SUBST(TINFO_DEP_SUFFIX)
1463 AC_SUBST(TINFO_LIB_SUFFIX)
1464 AC_SUBST(TINFO_ARGS)
1465
1466 # needed for Ada95
1467 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1468 AC_SUBST(TINFO_ARGS2)
1469
1470 AC_MSG_CHECKING(where we will install curses.h)
1471 test "$with_overwrite" = no && \
1472 test "x$includedir" = 'x${prefix}/include' && \
1473         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1474 AC_MSG_RESULT($includedir)
1475
1476 ### Resolve a conflict between normal and wide-curses by forcing applications
1477 ### that will need libutf8 to add it to their configure script.
1478 if test "$with_overwrite" != no ; then
1479 if test "$NCURSES_LIBUTF8" = 1 ; then
1480         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1481         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1482 fi
1483 fi
1484
1485 AC_SUBST(WITH_OVERWRITE)
1486 AC_SUBST(TINFO_LIST)
1487 AC_SUBST(SHLIB_LIST)
1488
1489 ### predefined stuff for the test programs
1490 AC_DEFINE(HAVE_SLK_COLOR)
1491
1492 ### Construct the list of subdirectories for which we'll customize makefiles
1493 ### with the appropriate compile-rules.
1494
1495 CF_SRC_MODULES($modules_to_build)
1496 CF_DIRS_TO_MAKE
1497
1498 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATHSEP')
1499
1500 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1501
1502 ### Now that we're done running tests, add the compiler-warnings, if any
1503 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1504
1505 ### Define substitutions for header files to avoid name-pollution
1506 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1507 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1508 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1509
1510 ################################################################################
1511 test "$use_database" = yes && SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1512 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1513 AC_OUTPUT( \
1514         include/MKterm.h.awk \
1515         include/curses.head:include/curses.h.in \
1516         include/termcap.h \
1517         include/unctrl.h \
1518         $SUB_MAKEFILES \
1519         Makefile,[
1520 CF_PRG_RULES([$srcdir/test/mk-test.awk ECHO_LINK="$ECHO_LINK"], test)
1521 CF_LIB_RULES($SRC_SUBDIRS)
1522 ],[
1523 ### Special initialization commands, used to pass information from the
1524 ### configuration-run into config.status
1525
1526 AWK="$AWK"
1527 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1528 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1529 ECHO_LINK="$ECHO_LINK"
1530 LDCONFIG="$LDCONFIG"
1531 LIB_NAME="$LIB_NAME"
1532 LIB_SUBSETS="$LIB_SUBSETS"
1533 LIB_SUFFIX="$LIB_SUFFIX"
1534 LIB_TRACING="$LIB_TRACING"
1535 MAKE_TERMINFO="$MAKE_TERMINFO"
1536 NCURSES_MAJOR="$NCURSES_MAJOR"
1537 NCURSES_MINOR="$NCURSES_MINOR"
1538 NCURSES_OSPEED="$NCURSES_OSPEED"
1539 NCURSES_PATCH="$NCURSES_PATCH"
1540 SRC_SUBDIRS="$SRC_SUBDIRS"
1541 TERMINFO="$TERMINFO"
1542 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1543 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1544 TINFO_NAME="$TINFO_NAME"
1545 WITH_CURSES_H="$with_curses_h"
1546 WITH_ECHO="$with_echo"
1547 WITH_OVERWRITE="$with_overwrite"
1548 cf_LIST_MODELS="$cf_list_models"
1549 cf_cv_abi_version="$cf_cv_abi_version"
1550 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1551 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1552 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1553 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1554 cf_cv_rel_version="$cf_cv_rel_version"
1555 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1556 cf_cv_shlib_version="$cf_cv_shlib_version"
1557 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1558 cf_cv_system_name="$cf_cv_system_name"
1559 cf_with_cxx_binding="$cf_with_cxx_binding"
1560 host="$host"
1561 target="$target"
1562
1563 ],cat)dnl
1564 ${MAKE-make} preinstall