configure.in

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2022,2023 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: configure.in,v 1.762 2023/04/22 22:16:28 tom Exp $
  33 dnl Process this file with autoconf to produce a configure script.
  34 dnl
  35 dnl For additional information, see
  36 dnl     https://invisible-island.net/autoconf/
  37 dnl     https://invisible-island.net/autoconf/my-autoconf.html
  38 dnl
  39 dnl ---------------------------------------------------------------------------
  40 AC_PREREQ(2.52.20210101)
  41 AC_REVISION($Revision: 1.762 $)
  42 AC_INIT(ncurses/base/lib_initscr.c)
  43 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  44
  45 AC_DEFUN([AC_PATH_XTRA],[])dnl ignore dependencies on this
  46
  47 CF_TOP_BUILDDIR
  48 CF_SUBST_NCURSES_VERSION
  49 CF_VERSION_INFO(NCURSES,ncurses)
  50
  51 CF_WITH_REL_VERSION(NCURSES)
  52 CF_NCURSES_WITH_ABI_VERSION
  53
  54 CF_WITH_SYSTYPE
  55
  56 ###     Save the given $CFLAGS to allow user-override.
  57 cf_user_CFLAGS="$CFLAGS"
  58
  59 ###     Default install-location
  60 CF_CFG_DEFAULTS
  61 ### Defaults for ncurses ABI
  62 CF_ABI_DEFAULTS
  63
  64 ### override ABI version, e.g., packagers
  65 CF_WITH_ABI_ALTERED
  66
  67 ###     Checks for programs.
  68 AC_ARG_WITH(ada,
  69         [  --without-ada           suppress check for Ada compiler, don't build demo],
  70         [cf_with_ada=$withval],
  71         [cf_with_ada=yes])
  72
  73 if test "x$cf_with_ada" = xyes
  74 then
  75         cf_prog_cc="gnatgcc gcc cc"
  76 else
  77         cf_prog_cc="gcc cc"
  78 fi
  79 CF_PROG_CC($cf_prog_cc)
  80
  81 AC_PROG_CPP
  82 AC_PROG_GCC_TRADITIONAL
  83 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
  84 CF_PROG_LDCONFIG
  85
  86 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  87 dnl                             configure script by not letting us test if C++
  88 dnl                             is present, making this option necessary.
  89 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  90 AC_ARG_WITH(cxx,
  91         [  --without-cxx           do not adjust ncurses bool to match C++],
  92         [cf_with_cxx=$withval],
  93         [cf_with_cxx=yes])
  94 AC_MSG_RESULT($cf_with_cxx)
  95 if test "X$cf_with_cxx" = Xno ; then
  96         CXX=""
  97         GXX=""
  98 else
  99         # with autoconf 2.13, we can change the error to a warning:
 100         pushdef([AC_MSG_ERROR],
 101                 [AC_MSG_RESULT(no)
 102                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
 103                 cf_with_cxx=no; CXX=""; GXX="";])dnl
 104         AC_PROG_CXX
 105         popdef([AC_MSG_ERROR])dnl
 106
 107         AC_LANG_PUSH(C++)
 108         if test "x$cf_with_cxx" != xno
 109         then
 110                 # Several of the C++ configurations do not work, particularly when
 111                 # cross-compiling (20140913 -TD)
 112                 AC_MSG_CHECKING(if $CXX works)
 113
 114                 save_CPPFLAGS="$CPPFLAGS"
 115                 eval cf_includedir=${includedir}
 116                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
 117                 AC_TRY_COMPILE([
 118 #include <stdlib.h>
 119 #include <stdio.h>
 120 ],
 121                 [
 122                 printf("Hello world!\n")
 123                 ],
 124                 [cf_cxx_works=yes],
 125                 [cf_cxx_works=no])
 126                 CPPFLAGS="$save_CPPFLAGS"
 127
 128                 AC_MSG_RESULT($cf_cxx_works)
 129                 if test "x$cf_cxx_works" = xno
 130                 then
 131                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
 132                         cf_with_cxx=no; CXX=""; GXX="";
 133                 fi
 134         fi
 135         AC_LANG_POP
 136
 137         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
 138         if test "$CXX" = "g++" ; then
 139                 AC_PATH_PROG(CXX,g++)
 140         fi
 141         case "x$CXX" in
 142         (x|xg++)
 143                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
 144                 cf_with_cxx=no; CXX=""; GXX="";
 145                 ;;
 146         esac
 147 fi
 148
 149 CF_GXX_VERSION
 150 case "$GXX_VERSION" in
 151 ([[1-9]][[0-9]].*)
 152         ;;
 153 (1.*|2.[[0-6]]*)
 154         AC_MSG_WARN(templates do not work)
 155         ;;
 156 esac
 157
 158 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 159 AC_ARG_WITH(cxx-binding,
 160         [  --without-cxx-binding   do not build C++ binding and demo],
 161         [cf_with_cxx_binding=$withval],
 162         [cf_with_cxx_binding=$cf_with_cxx])
 163 AC_MSG_RESULT($cf_with_cxx_binding)
 164
 165 AC_MSG_CHECKING(if you want to build with Ada)
 166 AC_MSG_RESULT($cf_with_ada)
 167
 168 AC_MSG_CHECKING(if you want to install terminal database)
 169 AC_ARG_ENABLE(db-install,
 170         [  --disable-db-install    suppress install of terminal database],
 171         [cf_with_db_install=$enableval],
 172         [cf_with_db_install=yes])
 173 AC_MSG_RESULT($cf_with_db_install)
 174
 175 AC_MSG_CHECKING(if you want to install manpages)
 176 AC_ARG_WITH(manpages,
 177         [  --without-manpages      suppress install of manpages],
 178         [cf_with_manpages=$withval],
 179         [cf_with_manpages=yes])
 180 AC_MSG_RESULT($cf_with_manpages)
 181
 182 AC_MSG_CHECKING(if you want to build programs such as tic)
 183 AC_ARG_WITH(progs,
 184         [  --without-progs         suppress build/install with programs (e.g., tic)],
 185         [cf_with_progs=$withval],
 186         [cf_with_progs=yes])
 187 AC_MSG_RESULT($cf_with_progs)
 188
 189 AC_MSG_CHECKING(if you want to build test-programs)
 190 AC_ARG_WITH(tests,
 191         [  --without-tests         suppress build/install with test-programs],
 192         [cf_with_tests=$withval],
 193         [cf_with_tests=yes])
 194 AC_MSG_RESULT($cf_with_tests)
 195
 196 AC_MSG_CHECKING(if you wish to install curses.h)
 197 AC_ARG_WITH(curses-h,
 198         [  --without-curses-h      install curses.h as ncurses.h only],
 199         [with_curses_h=$withval],
 200         [with_curses_h=yes])
 201 AC_MSG_RESULT($with_curses_h)
 202
 203 modules_to_build="ncurses"
 204 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
 205 modules_to_build="$modules_to_build panel menu form"
 206
 207 AC_ARG_PROGRAM
 208
 209 CF_PROG_AWK
 210 CF_PROG_INSTALL
 211 CF_PROG_LINT
 212 CF_PROG_LN_S
 213
 214 AC_SYS_LONG_FILE_NAMES
 215
 216 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
 217 # of package conflict.
 218 cf_config_suffix=
 219 AC_ARG_WITH(config-suffix,
 220         [  --with-config-suffix=X  suffixes ncursesXX-config file],
 221         [case "x$withval" in
 222         (xyes|xno)
 223                 AC_MSG_WARN(expected a value for config-suffix option)
 224                 ;;
 225         (*)     cf_config_suffix="$withval"
 226                 ;;
 227         esac])
 228 AC_SUBST(cf_config_suffix)
 229
 230 # If we find pkg-config, check if we should install the ".pc" files.
 231 CF_PKG_CONFIG
 232 CF_WITH_PKG_CONFIG_LIBDIR
 233 CF_ENABLE_PC_FILES
 234 if test -z "$MAKE_PC_FILES"
 235 then
 236         AC_MSG_CHECKING(for suffix to add to pc-files)
 237 AC_ARG_WITH(pc-suffix,
 238         [  --with-pc-suffix        suffixes pc-files],
 239         [case "x$withval" in
 240         (xyes|xno)
 241                 PC_MODULE_SUFFIX=
 242                 ;;
 243         (*)     PC_MODULE_SUFFIX="$withval"
 244                 ;;
 245         esac])
 246         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
 247         AC_MSG_RESULT($PC_MODULE_SUFFIX)
 248         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
 249         AC_SUBST(PC_MODULE_SUFFIX)
 250 fi
 251
 252 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 253 AC_ARG_ENABLE(mixed-case,
 254         [  --enable-mixed-case     tic should assume mixed-case filenames],
 255         [enable_mixedcase=$enableval],
 256         [enable_mixedcase=auto])
 257 AC_MSG_RESULT($enable_mixedcase)
 258 if test "$enable_mixedcase" = "auto" ; then
 259         CF_MIXEDCASE_FILENAMES
 260 else
 261         cf_cv_mixedcase=$enable_mixedcase
 262         if test "x$enable_mixedcase" = "xyes" ; then
 263                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
 264         fi
 265 fi
 266
 267 # do this after mixed-case option (tags/TAGS is not as important as tic).
 268 AC_PROG_MAKE_SET
 269 CF_MAKE_PHONY
 270 CF_MAKE_TAGS
 271 CF_MAKEFLAGS
 272
 273 dnl These are standard among *NIX systems, but not when cross-compiling
 274 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 275 AC_CHECK_TOOL(LD, ld, ld)
 276 AC_CHECK_TOOL(AR, ar, ar)
 277 AC_CHECK_TOOL(NM, nm, nm)
 278 CF_AR_FLAGS
 279
 280 dnl Special option for use by system-builders: the install-prefix is used to
 281 dnl adjust the location into which the actual install is done, so that an
 282 dnl archive can be built without modifying the host system's configuration.
 283 AC_MSG_CHECKING(if you have specified an install-prefix)
 284 AC_ARG_WITH(install-prefix,
 285         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 286         [case "x$withval" in
 287         (xyes|xno)
 288                 ;;
 289         (*)     DESTDIR="$withval"
 290                 ;;
 291         esac])
 292 AC_MSG_RESULT($DESTDIR)
 293 AC_SUBST(DESTDIR)
 294
 295 ###############################################################################
 296 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 297 # If we're cross-compiling, allow the user to override the tools and their
 298 # options.  The configure script is oriented toward identifying the host
 299 # compiler, etc., but we need a build compiler to generate parts of the source.
 300
 301 case "$cf_cv_system_name" in
 302 (*-msvc*)
 303         LDFLAGS="$LDFLAGS user32.lib"
 304         export LDFLAGS
 305         ;;
 306 esac
 307
 308 CF_BUILD_CC
 309
 310 ###############################################################################
 311 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 312
 313 ### Options to allow the user to specify the set of libraries which are used.
 314 ### Use "--without-normal --with-shared" to allow the default model to be
 315 ### shared, for example.
 316 cf_list_models=""
 317 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 318
 319 CF_WITH_LIBTOOL
 320 if test "$with_libtool" != "no" ; then
 321
 322 cf_list_models="$cf_list_models libtool"
 323
 324 else
 325
 326 AC_MSG_CHECKING(if you want to build shared libraries)
 327 AC_ARG_WITH(shared,
 328         [  --with-shared           generate shared-libraries],
 329         [with_shared=$withval],
 330         [with_shared=no])
 331 AC_MSG_RESULT($with_shared)
 332 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
 333
 334 AC_MSG_CHECKING(if you want to build static libraries)
 335 AC_ARG_WITH(normal,
 336         [  --with-normal           generate normal-libraries (default)],
 337         [with_normal=$withval],
 338         [with_normal=yes])
 339 AC_MSG_RESULT($with_normal)
 340 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
 341
 342 AC_MSG_CHECKING(if you want to build debug libraries)
 343 AC_ARG_WITH(debug,
 344         [  --with-debug            generate debug-libraries (default)],
 345         [with_debug=$withval],
 346         [with_debug=yes])
 347 AC_MSG_RESULT($with_debug)
 348 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
 349
 350 AC_MSG_CHECKING(if you want to build profiling libraries)
 351 AC_ARG_WITH(profile,
 352         [  --with-profile          generate profile-libraries],
 353         [with_profile=$withval],
 354         [with_profile=no])
 355 AC_MSG_RESULT($with_profile)
 356 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
 357
 358 fi
 359
 360 if test "X$cf_with_cxx_binding" != Xno; then
 361 if test "x$with_shared" = "xyes"; then
 362 AC_MSG_CHECKING(if you want to build C++ shared libraries)
 363 AC_ARG_WITH(cxx-shared,
 364         [  --with-cxx-shared       generate C++ shared-libraries],
 365         [with_shared_cxx=$withval],
 366         [with_shared_cxx=no])
 367 AC_MSG_RESULT($with_shared_cxx)
 368 fi
 369 fi
 370
 371 ###############################################################################
 372
 373 AC_MSG_CHECKING(for specified models)
 374 test -z "$cf_list_models" && cf_list_models=normal
 375 dnl If we use libtool to generate libraries, then it must be the only
 376 dnl specified model.
 377 test "$with_libtool" != "no" && cf_list_models=libtool
 378 AC_MSG_RESULT($cf_list_models)
 379
 380 ### Use the first model as the default, and save its suffix for use in building
 381 ### up test-applications.
 382 AC_MSG_CHECKING(for default model)
 383 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 384 AC_MSG_RESULT($DFT_LWR_MODEL)
 385
 386 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 387
 388 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 389 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 390
 391 TICS_NAME=tic
 392 AC_SUBST(TICS_NAME)
 393
 394 TINFO_NAME=tinfo
 395 AC_SUBST(TINFO_NAME)
 396
 397 LIB_NAME=ncurses
 398 AC_SUBST(LIB_NAME)
 399
 400 LIB_DIR=../lib
 401 LIB_2ND=../../lib
 402
 403 CF_WITH_LIB_PREFIX(cf_prefix)
 404
 405 LIB_SUFFIX=
 406 AC_SUBST(LIB_SUFFIX)
 407 CF_PATHSEP
 408
 409 # headers needed for checks...
 410 AC_CHECK_DECL(exit)
 411 AC_HEADER_DIRENT
 412
 413 ###############################################################################
 414
 415 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 416 AC_ARG_WITH(termlib,
 417         [  --with-termlib          generate separate terminfo library],
 418         [with_termlib=$withval],
 419         [with_termlib=no])
 420 AC_MSG_RESULT($with_termlib)
 421
 422 AC_MSG_CHECKING(if you want to build a separate tic library)
 423 AC_ARG_WITH(ticlib,
 424         [  --with-ticlib           generate separate tic library],
 425         [with_ticlib=$withval],
 426         [with_ticlib=no])
 427 AC_MSG_RESULT($with_ticlib)
 428
 429 dnl Not all ports of gcc support the -g option
 430
 431 if test X"$CC_G_OPT" = X"" ; then
 432         CC_G_OPT='-g'
 433         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
 434 fi
 435 AC_SUBST(CC_G_OPT)
 436
 437 if test X"$CXX_G_OPT" = X"" ; then
 438         CXX_G_OPT='-g'
 439         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
 440 fi
 441 AC_SUBST(CXX_G_OPT)
 442
 443 AC_MSG_CHECKING(for default loader flags)
 444 case "$DFT_LWR_MODEL" in
 445 (libtool) LD_MODEL=''   ;;
 446 (normal)  LD_MODEL=''   ;;
 447 (debug)   LD_MODEL=$CC_G_OPT ;;
 448 (profile) LD_MODEL='-pg';;
 449 (shared)  LD_MODEL=''   ;;
 450 esac
 451 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 452 AC_MSG_RESULT($LD_MODEL)
 453
 454 case "$DFT_LWR_MODEL" in
 455 (shared)
 456 CF_ENABLE_RPATH
 457 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 458 AC_ARG_ENABLE(relink,
 459 [  --disable-relink        relink shared libraries during install],
 460 [cf_cv_do_relink=$enableval],
 461 [cf_cv_do_relink=yes])
 462 AC_MSG_RESULT($cf_cv_do_relink)
 463         ;;
 464 esac
 465
 466 # we will build libraries one-level down.
 467 rel_builddir=..
 468 CF_SHARED_OPTS
 469 for model in $cf_list_models ; do
 470         case "$model" in
 471         (libtool)
 472                 CF_WITH_LIBTOOL_OPTS
 473                 CF_WITH_EXPORT_SYMS
 474                 ;;
 475         (shared)
 476                 if test "$CC_SHARED_OPTS" = "unknown"; then
 477                         AC_ERROR(Shared libraries are not supported in this version)
 478                 fi
 479                 # workaround for inept transition to PIE vs PIC...
 480                 AC_MSG_CHECKING(if current CFLAGS link properly)
 481                 AC_TRY_LINK(
 482                         [#include <stdio.h>],
 483                         [printf("Hello work\\n");],
 484                         [cf_cflags_work=yes],
 485                         [cf_cflags_work=no])
 486                 AC_MSG_RESULT($cf_cflags_work)
 487                 if test "$cf_cflags_work" = no
 488                 then
 489                         CF_VERBOSE(try to work around by appending shared-options)
 490                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
 491                 fi
 492                 CF_WITH_VERSIONED_SYMS
 493                 ;;
 494         esac
 495 done
 496
 497 ### Checks for special libraries, must be done up-front.
 498 SHLIB_LIST=""
 499 CF_WITH_GPM
 500 if test "$with_gpm" != no ; then
 501         AC_MSG_CHECKING(if you want to load GPM dynamically)
 502         AC_ARG_WITH(dlsym,
 503                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 504                 [with_dlsym=$withval],
 505                 [with_dlsym=yes])
 506         AC_MSG_RESULT($with_dlsym)
 507         if test "x$with_dlsym" = xyes ; then
 508                 CF_FUNC_DLSYM
 509                 if test "x$with_gpm" != xyes ; then
 510                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 511                         cf_cv_gpm_soname="$with_gpm"
 512                 else
 513                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 514                 fi
 515                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
 516                 SHLIB_LIST="-ldl $SHLIB_LIST"
 517                 CF_ADD_LIB(dl,PRIVATE_LIBS)
 518         else
 519                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 520                 CF_ADD_LIB(gpm,TEST_LIBS)
 521                 CF_ADD_LIB(gpm,PRIVATE_LIBS)
 522         fi
 523         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
 524         CF_CHECK_GPM_WGETCH
 525 fi
 526
 527 CF_WITH_PCRE2
 528 CF_WITH_SYSMOUSE
 529
 530 # pretend that ncurses==ncursesw==ncursest
 531 AC_MSG_CHECKING(if you want to disable library suffixes)
 532 CF_ARG_DISABLE(lib-suffixes,
 533         [  --disable-lib-suffixes  disable library suffixes],
 534         [disable_lib_suffixes=yes],
 535         [disable_lib_suffixes=no],
 536         no)
 537 AC_MSG_RESULT($disable_lib_suffixes)
 538
 539 ### If we're building with rpath, try to link non-standard libs that way too.
 540 if test "$DFT_LWR_MODEL" = "shared" && test "x$cf_cv_enable_rpath" != xno; then
 541         CF_DISABLE_RPATH_HACK
 542 fi
 543
 544 ### Depending on the system, someone may use rpath to build ncurses but not
 545 # want users of the package to rely upon that feature.  Give those people an
 546 # option to suppress that detail from EXTRA_LDFLAGS.
 547 EXTRA_PKG_LDFLAGS="$LDFLAGS $EXTRA_LDFLAGS"
 548 if test -n "$EXTRA_PKG_LDFLAGS"
 549 then
 550         AC_MSG_CHECKING(if you want to disable extra LDFLAGS for package-scripts)
 551         CF_ARG_DISABLE(pkg-ldflags,
 552                 [  --disable-pkg-ldflags   disable extra LDFLAGS for package-scripts],
 553                 [disable_pkg_ldflags=yes],
 554                 [disable_pkg_ldflags=no],
 555                 no)
 556         AC_MSG_RESULT($disable_pkg_ldflags)
 557         test "$disable_pkg_ldflags" = yes && EXTRA_PKG_LDFLAGS=
 558 fi
 559 AC_SUBST(EXTRA_PKG_LDFLAGS)
 560
 561 ###############################################################################
 562 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 563
 564 ###     use option --with-extra-suffix to append suffix to headers and libraries
 565 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
 566 EXTRA_SUFFIX=
 567 AC_ARG_WITH(extra-suffix,
 568         [  --with-extra-suffix=X   append extra suffix to header/library paths],
 569         [case x$withval in
 570         (xno)
 571                 ;;
 572         (xyes|x)
 573                 EXTRA_SUFFIX=$cf_cv_abi_version
 574                 ;;
 575         (*)
 576                 EXTRA_SUFFIX=$withval
 577                 ;;
 578         esac
 579         ])
 580 AC_MSG_RESULT($EXTRA_SUFFIX)
 581 AC_SUBST(EXTRA_SUFFIX)
 582
 583 ###     use option --disable-overwrite to leave out the link to -lcurses
 584 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 585 AC_ARG_ENABLE(overwrite,
 586         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
 587         [with_overwrite=$enableval],
 588         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 589 AC_MSG_RESULT($with_overwrite)
 590
 591 AC_MSG_CHECKING(if external terminfo-database is used)
 592 AC_ARG_ENABLE(database,
 593         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 594         [use_database=$enableval],
 595         [use_database=yes])
 596 AC_MSG_RESULT($use_database)
 597
 598 case "$host_os" in
 599 (os2*)
 600         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 601         ;;
 602 (*)
 603         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 604         ;;
 605 esac
 606 AC_SUBST(TERMINFO_SRC)
 607
 608 NCURSES_USE_DATABASE=0
 609 if test "$use_database" != no ; then
 610         NCURSES_USE_DATABASE=1
 611
 612         AC_MSG_CHECKING(which terminfo source-file will be installed)
 613         AC_ARG_WITH(database,
 614                 [  --with-database=XXX     specify terminfo source to install],
 615                 [TERMINFO_SRC=$withval])
 616         AC_MSG_RESULT($TERMINFO_SRC)
 617
 618         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 619         AC_ARG_WITH(hashed-db,
 620                 [  --with-hashed-db        specify hashed-database library],,
 621                 [with_hashed_db=no])
 622         AC_MSG_RESULT($with_hashed_db)
 623 else
 624         with_hashed_db=no
 625 fi
 626 AC_SUBST(NCURSES_USE_DATABASE)
 627
 628 AC_MSG_CHECKING(for list of fallback descriptions)
 629 AC_ARG_WITH(fallbacks,
 630         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 631         [with_fallback=$withval],
 632         [with_fallback=])
 633 AC_MSG_RESULT($with_fallback)
 634
 635 case ".$with_fallback" in
 636 (.|.no)
 637         FALLBACK_LIST=
 638         ;;
 639 (.yes)
 640         AC_MSG_WARN(expected a list of terminal descriptions)
 641         ;;
 642 (*)
 643         FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 644         ;;
 645 esac
 646
 647 # The fallback feature in ncurses relies upon tic/infocmp outside the build
 648 # tree for generating the terminal descriptions that will be compiled into the
 649 # library.  If your toolchain is old, it may not handle current terminal
 650 # databases.  Use configure-options to point to the tools which will be used,
 651 # rather than the first ones found on the $PATH.
 652 AC_CHECK_TOOL(TIC, tic)
 653 AC_CHECK_TOOL(INFOCMP, infocmp)
 654 if test -n "$FALLBACK_LIST"
 655 then
 656         CF_WITH_PATH_PROG(TIC,     tic,     [for fallbacks], $PATH:/usr/local/ncurses/bin)
 657         CF_WITH_PATH_PROG(INFOCMP, infocmp, [for fallbacks], $PATH:/usr/local/ncurses/bin)
 658         test -z "$TIC" && FALLBACK_LIST=
 659         test -z "$INFOCMP" && FALLBACK_LIST=
 660         if test -z "$FALLBACK_LIST"
 661         then
 662                 AC_MSG_WARN(ignoring fallback option because tic/infocmp are not available)
 663         fi
 664 fi
 665 AC_SUBST(TIC)
 666 AC_SUBST(INFOCMP)
 667
 668 USE_FALLBACKS=
 669 test -z "$FALLBACK_LIST" && USE_FALLBACKS="#"
 670 AC_SUBST(FALLBACK_LIST)
 671 AC_SUBST(USE_FALLBACKS)
 672
 673 AC_MSG_CHECKING(if you want modern xterm or antique)
 674 AC_ARG_WITH(xterm-new,
 675         [  --without-xterm-new     specify if xterm terminfo should be old version],
 676         [with_xterm_new=$withval],
 677         [with_xterm_new=yes])
 678 case "$with_xterm_new" in
 679 (no) with_xterm_new=xterm-old;;
 680 (*)      with_xterm_new=xterm-new;;
 681 esac
 682 AC_MSG_RESULT($with_xterm_new)
 683 WHICH_XTERM=$with_xterm_new
 684 AC_SUBST(WHICH_XTERM)
 685
 686 case $host_os in
 687 (*linux-gnu|*cygwin|*mingw32|*msys)
 688         want_xterm_kbs=DEL
 689         ;;
 690 (*)
 691         want_xterm_kbs=BS
 692         ;;
 693 esac
 694
 695 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 696 AC_ARG_WITH(xterm-kbs,
 697         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
 698         [with_xterm_kbs=$withval],
 699         [with_xterm_kbs=BS])
 700 case x$with_xterm_kbs in
 701 (xyes|xno|xBS|xbs|x8)
 702         with_xterm_kbs=BS
 703         ;;
 704 (xDEL|xdel|x127)
 705         with_xterm_kbs=DEL
 706         ;;
 707 (*)
 708         with_xterm_kbs=$withval
 709         ;;
 710 esac
 711 AC_MSG_RESULT($with_xterm_kbs)
 712 XTERM_KBS=$with_xterm_kbs
 713 AC_SUBST(XTERM_KBS)
 714
 715 if test "x$with_xterm_kbs" != "x$want_xterm_kbs"
 716 then
 717         AC_MSG_WARN(expected --with-xterm-kbs=$want_xterm_kbs for $host_os)
 718 fi
 719
 720 MAKE_TERMINFO=
 721 if test "$use_database" = no ; then
 722         TERMINFO="${datadir}/terminfo"
 723         MAKE_TERMINFO="#"
 724 else
 725
 726 AC_MSG_CHECKING(for list of terminfo directories)
 727 CF_WITH_PATHLIST(terminfo-dirs,
 728         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 729         TERMINFO_DIRS,
 730         DATADIR/terminfo,
 731         ${datadir}/terminfo)
 732 AC_MSG_RESULT($TERMINFO_DIRS)
 733 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
 734
 735 case "x$TERMINFO" in
 736 x???:*)
 737         AC_MSG_WARN(ignoring non-directory/file TERMINFO value)
 738         unset TERMINFO
 739         ;;
 740 esac
 741
 742 AC_MSG_CHECKING(for default terminfo directory)
 743 CF_WITH_PATH(default-terminfo-dir,
 744         [  --with-default-terminfo-dir=DIR default terminfo directory],
 745         TERMINFO,
 746         DATADIR/terminfo,
 747         ${datadir}/terminfo)
 748 AC_MSG_RESULT($TERMINFO)
 749 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
 750
 751 fi
 752
 753 AC_SUBST(TERMINFO)
 754 AC_SUBST(MAKE_TERMINFO)
 755
 756 ###     use option --disable-big-core to make tic run on small machines
 757 ###     We need 4Mb, check if we can allocate 50% more than that.
 758 AC_MSG_CHECKING(if big-core option selected)
 759 AC_ARG_ENABLE(big-core,
 760         [  --disable-big-core      assume machine has little memory],
 761         [with_big_core=$enableval],
 762         [AC_TRY_RUN([
 763 #include <stdlib.h>
 764 #include <string.h>
 765 int main() {
 766         unsigned long n = 6000000L;
 767         char *s = malloc(n);
 768         if (s != 0)
 769                 s[0] = s[n-1] = 0;
 770         ${cf_cv_main_return:-return}(s == 0);
 771 }],
 772         [with_big_core=yes],
 773         [with_big_core=no],
 774         [with_big_core=no])])
 775 AC_MSG_RESULT($with_big_core)
 776 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
 777
 778 ### ISO C only guarantees 512-char strings, we have tables which load faster
 779 ### when constructed using "big" strings.  More than the C compiler, the awk
 780 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 781 AC_MSG_CHECKING(if big-strings option selected)
 782 AC_ARG_ENABLE(big-strings,
 783         [  --disable-big-strings   assume compiler has only standard-size strings],
 784         [with_big_strings=$enableval],
 785         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 786 AC_MSG_RESULT($with_big_strings)
 787
 788 USE_BIG_STRINGS=0
 789 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
 790 AC_SUBST(USE_BIG_STRINGS)
 791
 792 ###     use option --enable-termcap to compile in the termcap fallback support
 793 AC_MSG_CHECKING(if you want termcap-fallback support)
 794 AC_ARG_ENABLE(termcap,
 795         [  --enable-termcap        compile in termcap fallback support],
 796         [with_termcap=$enableval],
 797         [with_termcap=no])
 798 AC_MSG_RESULT($with_termcap)
 799
 800 NCURSES_USE_TERMCAP=0
 801 if test "x$with_termcap" != "xyes" ; then
 802         if test "$use_database" = no ; then
 803                 if test -z "$with_fallback" ; then
 804                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 805                 fi
 806         fi
 807         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
 808 else
 809
 810         if test "$with_ticlib" != no ; then
 811                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 812         fi
 813
 814         NCURSES_USE_TERMCAP=1
 815         AC_MSG_CHECKING(for list of termcap files)
 816         CF_WITH_PATHLIST(termpath,
 817                 [  --with-termpath=XXX     specify list of termcap files],
 818                 TERMPATH,
 819                 /etc/termcap:/usr/share/misc/termcap)
 820         AC_MSG_RESULT($TERMPATH)
 821         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
 822
 823         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 824         AC_MSG_CHECKING(if fast termcap-loader is needed)
 825         AC_ARG_ENABLE(getcap,
 826                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 827                 [with_getcap=$enableval],
 828                 [with_getcap=no])
 829         AC_MSG_RESULT($with_getcap)
 830         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
 831
 832         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 833         AC_ARG_ENABLE(getcap-cache,
 834                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 835                 [with_getcap_cache=$enableval],
 836                 [with_getcap_cache=no])
 837         AC_MSG_RESULT($with_getcap_cache)
 838         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
 839
 840 fi
 841 AC_SUBST(NCURSES_USE_TERMCAP)
 842
 843 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 844 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 845 AC_ARG_ENABLE(home-terminfo,
 846         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 847         [with_home_terminfo=$enableval],
 848         [with_home_terminfo=yes])
 849 AC_MSG_RESULT($with_home_terminfo)
 850 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
 851
 852 AC_MSG_CHECKING(if you want to permit root to use ncurses environment variables)
 853 AC_ARG_ENABLE(root-environ,
 854         [  --disable-root-environ  restrict root use of ncurses environment variables],
 855         [with_root_environ=$enableval],
 856         [with_root_environ=yes])
 857 AC_MSG_RESULT($with_root_environ)
 858 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if root/setuid application is allowed to use ncurses environment])
 859
 860 AC_MSG_CHECKING(if you want to permit setuid programs to access all files)
 861 AC_ARG_ENABLE(root-access,
 862         [  --disable-root-access   restrict file-access when running setuid],
 863         [with_root_access=$enableval],
 864         [with_root_access=yes])
 865 AC_MSG_RESULT($with_root_access)
 866 test "x$with_root_access" = xyes && AC_DEFINE(USE_ROOT_ACCESS,1,[Define to 1 if setuid is allowed all file-access])
 867
 868 AC_MSG_CHECKING(if you want to permit setuid use of ncurses environment variables)
 869 AC_ARG_ENABLE(setuid-environ,
 870         [  --disable-setuid-environ restrict setuid use of ncurses environment variables],
 871         [with_setuid_environ=$enableval],
 872         [with_setuid_environ=$with_root_environ])
 873 AC_MSG_RESULT($with_setuid_environ)
 874 test "x$with_setuid_environ" = xyes && AC_DEFINE(USE_SETUID_ENVIRON,1,[Define to 1 if setuid/setgid application is allowed to use ncurses environment])
 875
 876 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 877 ###   to reduce storage requirements for the terminfo database.
 878 CF_LINK_FUNCS
 879
 880 with_links=no
 881 with_symlinks=no
 882
 883 # soft links (symbolic links) are useful for some systems where hard links do
 884 # not work, or to make it simpler to copy terminfo trees around.
 885 if test "x$ac_cv_func_symlink" = xyes ; then
 886         AC_MSG_CHECKING(if tic should use symbolic links)
 887         AC_ARG_ENABLE(symlinks,
 888         [  --enable-symlinks       make tic use symbolic links not hard links],
 889         [with_symlinks=$enableval],
 890         [with_symlinks=no])
 891         AC_MSG_RESULT($with_symlinks)
 892 fi
 893
 894 # If we have hard links and did not choose to use soft links instead, there is
 895 # no reason to make this choice optional - use the hard links.
 896 if test "$with_symlinks" = no ; then
 897         AC_MSG_CHECKING(if tic should use hard links)
 898         if test "x$ac_cv_func_link" = xyes ; then
 899                 with_links=yes
 900         else
 901                 with_links=no
 902         fi
 903         AC_MSG_RESULT($with_links)
 904 fi
 905
 906 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
 907 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
 908
 909 ###   use option --enable-broken-linker to force on use of broken-linker support
 910 CF_ENABLE_BROKEN_LINKER
 911
 912 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 913 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 914 AC_ARG_ENABLE(bsdpad,
 915         [  --enable-bsdpad         recognize BSD-style prefix padding],
 916         [with_bsdpad=$enableval],
 917         [with_bsdpad=no])
 918 AC_MSG_RESULT($with_bsdpad)
 919 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
 920
 921 ###   use option --enable-widec to turn on use of wide-character support
 922 NCURSES_CH_T=chtype
 923 NCURSES_LIBUTF8=0
 924
 925 NEED_WCHAR_H=0
 926 NCURSES_MBSTATE_T=0
 927 NCURSES_WCHAR_T=0
 928 NCURSES_WINT_T=0
 929
 930 # Check to define _XOPEN_SOURCE "automatically"
 931 CPPFLAGS_before_XOPEN="$CPPFLAGS"
 932 CF_XOPEN_SOURCE(600)
 933 CPPFLAGS_after_XOPEN="$CPPFLAGS"
 934
 935 # Work around breakage on OS X
 936 CF_SIGWINCH
 937
 938 # Checks for CODESET support.
 939 AM_LANGINFO_CODESET
 940
 941 # use these variables to work around a defect in gcc's fixincludes.
 942 NCURSES_OK_WCHAR_T=
 943 NCURSES_OK_WINT_T=
 944
 945 AC_MSG_CHECKING(if you want wide-character code)
 946 AC_ARG_ENABLE(widec,
 947         [  --enable-widec          compile with wide-char/UTF-8 code],
 948         [with_widec=$enableval],
 949         [with_widec=no])
 950 AC_MSG_RESULT($with_widec)
 951
 952 NCURSES_WCWIDTH_GRAPHICS=1
 953 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
 954
 955 if test "x$with_widec" = xyes ; then
 956         if test "x$disable_lib_suffixes" = xno ; then
 957                 LIB_SUFFIX="w${LIB_SUFFIX}"
 958         fi
 959         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
 960         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
 961         case "$CPPFLAGS" in
 962         (*_XOPEN_SOURCE=*)
 963                 ;;
 964         (*)
 965                 AC_MSG_WARN(_XOPEN_SOURCE feature test macro appears to be predefined)
 966                 # CPPFLAGS="$CPPFLAGS -DNCURSES_WIDECHAR"
 967                 CPPFLAGS_after_XOPEN="$CPPFLAGS_after_XOPEN -DNCURSES_WIDECHAR"
 968                 ;;
 969         esac
 970
 971         CF_CHECK_WCHAR_H
 972         CF_CHECK_WCWIDTH_GRAPHICS
 973         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
 974
 975         # with_overwrite=no
 976         NCURSES_CH_T=cchar_t
 977         AC_CHECK_FUNCS(putwc btowc wctob wmemchr mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 978         if test "x$ac_cv_func_putwc" != xyes ; then
 979                 CF_UTF8_LIB
 980                 if test "$cf_cv_utf8_lib" != no ; then
 981                         NCURSES_LIBUTF8=1
 982                 fi
 983         fi
 984         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 985         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 986         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 987
 988         if test "$NCURSES_MBSTATE_T" != 0; then
 989                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
 990         fi
 991 fi
 992 AC_SUBST(NCURSES_CH_T)
 993 AC_SUBST(NCURSES_LIBUTF8)
 994
 995 AC_SUBST(NEED_WCHAR_H)
 996 AC_SUBST(NCURSES_MBSTATE_T)
 997 AC_SUBST(NCURSES_WCHAR_T)
 998 AC_SUBST(NCURSES_WINT_T)
 999
1000 AC_SUBST(NCURSES_OK_WCHAR_T)
1001 AC_SUBST(NCURSES_OK_WINT_T)
1002
1003 ###   use option --disable-lp64 to allow long chtype
1004 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
1005 AC_ARG_ENABLE(lp64,
1006         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
1007         [with_lp64=$enableval],
1008         [with_lp64=$cf_dft_with_lp64])
1009 AC_MSG_RESULT($with_lp64)
1010
1011 if test "x$with_lp64" = xyes ; then
1012         cf_cv_enable_lp64=1
1013 else
1014         cf_cv_enable_lp64=0
1015 fi
1016 AC_SUBST(cf_cv_enable_lp64)
1017
1018 CF_LARGEFILE
1019
1020 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
1021 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
1022 AC_ARG_ENABLE(tparm-varargs,
1023         [  --disable-tparm-varargs compile tparm() without varargs interface],
1024         [with_tparm_varargs=$enableval],
1025         [with_tparm_varargs=yes])
1026 AC_MSG_RESULT($with_tparm_varargs)
1027 NCURSES_TPARM_VARARGS=0
1028 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
1029 AC_SUBST(NCURSES_TPARM_VARARGS)
1030
1031 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
1032 if test "$with_ticlib" != no ; then
1033 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
1034 AC_ARG_ENABLE(tic-depends,
1035         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
1036         [with_tic_depends=$enableval],
1037         [with_tic_depends=yes])
1038 AC_MSG_RESULT($with_tic_depends)
1039 else
1040         with_tic_depends=no
1041 fi
1042
1043 ###   use option --enable-wattr-macros to enable wattr* macros in curses.h
1044 AC_MSG_CHECKING(if you want to enable wattr* macros)
1045 AC_ARG_ENABLE(wattr-macros,
1046         [  --enable-wattr-macros   enable wattr* macros],
1047         [with_wattr_macros=$enableval],
1048         [with_wattr_macros=no])
1049 if [[ "x$with_wattr_macros" != xyes ]]; then
1050         NCURSES_WATTR_MACROS=0
1051         AC_MSG_RESULT(no)
1052 else
1053         NCURSES_WATTR_MACROS=1
1054         AC_MSG_RESULT(yes)
1055 fi
1056 AC_SUBST(NCURSES_WATTR_MACROS)
1057
1058 CF_WITH_X11_RGB
1059
1060 ###   use option --with-bool to override bool's type
1061 AC_MSG_CHECKING(for type of bool)
1062 AC_ARG_WITH(bool,
1063         [  --with-bool=TYPE        override fallback type of bool variable],
1064         [NCURSES_BOOL="$withval"],
1065         [NCURSES_BOOL=auto])
1066 AC_MSG_RESULT($NCURSES_BOOL)
1067 AC_SUBST(NCURSES_BOOL)
1068
1069 AC_MSG_CHECKING(for alternate terminal capabilities file)
1070 AC_ARG_WITH(caps,
1071         [  --with-caps=alt         compile with alternate Caps file],
1072         [TERMINFO_CAPS=Caps.$withval],
1073         [TERMINFO_CAPS=Caps])
1074 if test ! -f "${srcdir}/include/${TERMINFO_CAPS}"
1075 then
1076         AC_MSG_WARN(file not found: "${srcdir}/include/${TERMINFO_CAPS}")
1077         TERMINFO_CAPS=Caps
1078 fi
1079 AC_MSG_RESULT($TERMINFO_CAPS)
1080 AC_SUBST(TERMINFO_CAPS)
1081
1082 ###   use option --with-chtype to override chtype's type
1083 AC_MSG_CHECKING(for type of chtype)
1084 AC_ARG_WITH(chtype,
1085         [  --with-chtype=TYPE      override type of chtype],
1086         [NCURSES_CHTYPE="$withval"],
1087         [NCURSES_CHTYPE=$cf_dft_chtype])
1088 AC_MSG_RESULT($NCURSES_CHTYPE)
1089
1090 ###   use option --with-ospeed to override ospeed's type
1091 AC_MSG_CHECKING(for type of ospeed)
1092 AC_ARG_WITH(ospeed,
1093         [  --with-ospeed=TYPE      override type of ospeed variable],
1094         [NCURSES_OSPEED="$withval"],
1095         [NCURSES_OSPEED=short])
1096 AC_MSG_RESULT($NCURSES_OSPEED)
1097 AC_SUBST(NCURSES_OSPEED)
1098
1099 ###   use option --with-mmask-t to override mmask_t's type
1100 AC_MSG_CHECKING(for type of mmask_t)
1101 AC_ARG_WITH(mmask-t,
1102         [  --with-mmask-t=TYPE     override type of mmask_t],
1103         [NCURSES_MMASK_T="$withval"],
1104         [NCURSES_MMASK_T=$cf_dft_mmask_t])
1105 AC_MSG_RESULT($NCURSES_MMASK_T)
1106
1107 ###   use option --with-ccharw-max to override CCHARW_MAX size
1108 AC_MSG_CHECKING(for size CCHARW_MAX)
1109 AC_ARG_WITH(ccharw-max,
1110         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1111         [NCURSES_CCHARW_MAX="$withval"],
1112         [NCURSES_CCHARW_MAX=$cf_dft_ccharw_max])
1113 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1114 AC_SUBST(NCURSES_CCHARW_MAX)
1115
1116 AC_CHECK_SIZEOF([signed char])
1117 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1118         NCURSES_SBOOL="signed char"
1119 else
1120         NCURSES_SBOOL="char"
1121 fi
1122 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1123 AC_ARG_ENABLE(signed-char,
1124         [  --enable-signed-char    compile using signed Boolean's in term.h],
1125         [with_signed_char=$enableval],
1126         [with_signed_char=$cf_dft_signed_char])
1127 AC_MSG_RESULT($with_signed_char)
1128 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1129 AC_SUBST(NCURSES_SBOOL)
1130
1131 ###   use option --with-tparm-arg to override tparm's argument type
1132 AC_MSG_CHECKING(for type of tparm args)
1133 AC_ARG_WITH(tparm-arg,
1134         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1135         [NCURSES_TPARM_ARG="$withval"],
1136         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1137 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1138 AC_SUBST(NCURSES_TPARM_ARG)
1139
1140 ### Enable compiling-in rcs id's
1141 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1142 AC_ARG_WITH(rcs-ids,
1143         [  --with-rcs-ids          compile-in RCS identifiers],
1144         [with_rcs_ids=$withval],
1145         [with_rcs_ids=no])
1146 AC_MSG_RESULT($with_rcs_ids)
1147 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1148
1149 ###############################################################################
1150 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1151
1152 ###############################################################################
1153 CF_HELP_MESSAGE(Extensions:)
1154
1155 ### Note that some functions (such as const) are normally disabled anyway.
1156 AC_MSG_CHECKING(if you want to build with function extensions)
1157 AC_ARG_ENABLE(ext-funcs,
1158         [  --disable-ext-funcs     disable function-extensions],
1159         [with_ext_funcs=$enableval],
1160         [with_ext_funcs=yes])
1161 AC_MSG_RESULT($with_ext_funcs)
1162 if test "x$with_ext_funcs" = xyes ; then
1163         NCURSES_EXT_FUNCS=1
1164         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1165         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1166         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1167         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1168         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1169         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1170         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1171         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1172         AC_DEFINE(HAVE_USE_EXTENDED_NAMES,1,[Define to 1 to enable use_extended_names() function in test-programs])
1173         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1174         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1175         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1176         GENERATED_EXT_FUNCS=generated
1177         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1178 else
1179         NCURSES_EXT_FUNCS=0
1180         GENERATED_EXT_FUNCS=
1181 fi
1182 AC_SUBST(NCURSES_EXT_FUNCS)
1183 AC_SUBST(GENERATED_EXT_FUNCS)
1184
1185 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1186 AC_ARG_ENABLE(sp-funcs,
1187         [  --enable-sp-funcs       enable SCREEN-extensions],
1188         [with_sp_funcs=$enableval],
1189         [with_sp_funcs=$cf_dft_ext_spfuncs])
1190 AC_MSG_RESULT($with_sp_funcs)
1191 if test "x$with_sp_funcs" = xyes ; then
1192         NCURSES_SP_FUNCS=1
1193         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1194         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1195         GENERATED_SP_FUNCS=generated
1196 else
1197         NCURSES_SP_FUNCS=0
1198         GENERATED_SP_FUNCS=
1199 fi
1200 AC_SUBST(NCURSES_SP_FUNCS)
1201 AC_SUBST(GENERATED_SP_FUNCS)
1202
1203 AC_MSG_CHECKING(if you want to build with terminal-driver)
1204 AC_ARG_ENABLE(term-driver,
1205         [  --enable-term-driver    enable terminal-driver],
1206         [with_term_driver=$enableval],
1207         [with_term_driver=no])
1208 AC_MSG_RESULT($with_term_driver)
1209 if test "x$with_term_driver" = xyes ; then
1210         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1211         if test "x$with_termlib" != xno ; then
1212                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1213         fi
1214         if test "x$with_sp_funcs" != xyes ; then
1215                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1216         fi
1217 fi
1218
1219 ###   use option --enable-const to turn on use of const beyond that in XSI.
1220 AC_MSG_CHECKING(for extended use of const keyword)
1221 AC_ARG_ENABLE(const,
1222         [  --enable-const          compile with extra/non-standard const],
1223         [with_ext_const=$enableval],
1224         [with_ext_const=$cf_dft_ext_const])
1225 AC_MSG_RESULT($with_ext_const)
1226 NCURSES_CONST='/*nothing*/'
1227 if test "x$with_ext_const" = xyes ; then
1228         NCURSES_CONST=const
1229 fi
1230 AC_SUBST(NCURSES_CONST)
1231
1232 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1233 AC_MSG_CHECKING(if you want to use extended colors)
1234 AC_ARG_ENABLE(ext-colors,
1235         [  --enable-ext-colors     compile for 256-color support],
1236         [with_ext_colors=$enableval],
1237         [with_ext_colors=$cf_dft_ext_colors])
1238 AC_MSG_RESULT($with_ext_colors)
1239 NCURSES_EXT_COLORS=0
1240 if test "x$with_ext_colors" = xyes ; then
1241         if test "x$with_widec" != xyes ; then
1242                 AC_MSG_WARN(This option applies only to wide-character library)
1243         else
1244                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1245                 CF_NCURSES_ABI_6
1246                 NCURSES_EXT_COLORS=1
1247                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1248                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1249                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1250                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1251         fi
1252 fi
1253 AC_SUBST(NCURSES_EXT_COLORS)
1254
1255 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1256 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1257 AC_ARG_ENABLE(ext-mouse,
1258         [  --enable-ext-mouse      compile for extended mouse-encoding],
1259         [with_ext_mouse=$enableval],
1260         [with_ext_mouse=$cf_dft_ext_mouse])
1261 AC_MSG_RESULT($with_ext_mouse)
1262 if test "x$with_ext_mouse" = xyes ; then
1263         CF_NCURSES_ABI_6
1264 fi
1265
1266 case $cf_cv_abi_default in
1267 (5)
1268         NCURSES_MOUSE_VERSION=1
1269         ;;
1270 (6)
1271         NCURSES_MOUSE_VERSION=2
1272         ;;
1273 ([[789]])
1274         NCURSES_MOUSE_VERSION=3
1275         ;;
1276 esac
1277
1278 AC_SUBST(NCURSES_MOUSE_VERSION)
1279
1280 ###   use option --enable-ext-putwin to turn on extended screendumps
1281 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1282 AC_ARG_ENABLE(ext-putwin,
1283         [  --enable-ext-putwin     compile with extended putwin/screendump],
1284         [with_ext_putwin=$enableval],
1285         [with_ext_putwin=$cf_dft_ext_putwin])
1286 AC_MSG_RESULT($with_ext_putwin)
1287 if test "x$with_ext_putwin" = xyes ; then
1288         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1289 fi
1290
1291 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1292 AC_ARG_ENABLE(no-padding,
1293         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1294         [with_no_padding=$enableval],
1295         [with_no_padding=$with_ext_funcs])
1296 AC_MSG_RESULT($with_no_padding)
1297 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1298
1299 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1300 AC_MSG_CHECKING(if you want SIGWINCH handler)
1301 AC_ARG_ENABLE(sigwinch,
1302         [  --enable-sigwinch       compile with SIGWINCH handler],
1303         [with_sigwinch=$enableval],
1304         [with_sigwinch=$with_ext_funcs])
1305 AC_MSG_RESULT($with_sigwinch)
1306 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1307
1308 ###   use option --enable-tcap-names to allow user to define new capabilities
1309 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1310 AC_ARG_ENABLE(tcap-names,
1311         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1312         [with_tcap_names=$enableval],
1313         [with_tcap_names=$with_ext_funcs])
1314 AC_MSG_RESULT($with_tcap_names)
1315 NCURSES_XNAMES=0
1316 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1317 AC_SUBST(NCURSES_XNAMES)
1318
1319 ##############################################################################
1320 CF_HELP_MESSAGE(Reentrant Code:)
1321 CF_WITH_PTHREAD
1322
1323 if test "x$with_pthread" != xno; then
1324         AC_CHECK_FUNC(pthread_kill,[
1325                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1326                 AC_ARG_ENABLE(pthreads-eintr,
1327                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1328                         [use_pthreads_eintr=$enableval],
1329                         [use_pthreads_eintr=no])
1330                 AC_MSG_RESULT($use_pthreads_eintr)
1331                 if test "x$use_pthreads_eintr" = xyes ; then
1332                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1333                 fi])
1334
1335         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1336         AC_ARG_ENABLE(weak-symbols,
1337                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1338                 [use_weak_symbols=$enableval],
1339                 [use_weak_symbols=no])
1340         AC_MSG_RESULT($use_weak_symbols)
1341         if test "x$use_weak_symbols" = xyes ; then
1342                 CF_WEAK_SYMBOLS
1343         else
1344                 cf_cv_weak_symbols=no
1345         fi
1346
1347         if test "x$cf_cv_weak_symbols" = xyes ; then
1348                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1349         fi
1350 fi
1351
1352 PTHREAD=
1353 if test "x$with_pthread" = "xyes" ; then
1354         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1355         enable_reentrant=yes
1356         if test "x$cf_cv_weak_symbols" = xyes ; then
1357                 PTHREAD=-lpthread
1358                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1359         fi
1360 fi
1361 AC_SUBST(PTHREAD)
1362
1363 # Reentrant code has to be opaque; there's little advantage to making ncurses
1364 # opaque outside of that, so there is no --enable-opaque option.  We can use
1365 # this option without --with-pthreads, but this will be always set for
1366 # pthreads.
1367 AC_MSG_CHECKING(if you want reentrant code)
1368 AC_ARG_ENABLE(reentrant,
1369         [  --enable-reentrant      compile with reentrant code],
1370         [with_reentrant=$enableval],
1371         [with_reentrant=no])
1372 AC_MSG_RESULT($with_reentrant)
1373 if test "x$with_reentrant" = xyes ; then
1374         cf_cv_enable_reentrant=1
1375         cf_cv_enable_opaque="NCURSES_INTERNALS"
1376         NCURSES_SIZE_T=int
1377         if test "x$cf_cv_weak_symbols" = xyes ; then
1378                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1379                 CF_ADD_LIB(pthread,TEST_LIBS)
1380                 CF_ADD_LIB(pthread,TEST_LIBS2)
1381                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1382         else
1383                 # when not using weak symbols but with_reentrant,
1384                 # add 't' to the library suffix on all platforms
1385                 # except cygwin, where we only do that if ALSO
1386                 # compiling with full thread support.
1387                 case "$host" in
1388                 (*cygwin* | *msys*)
1389                         if test "$with_pthread" = "yes" ; then
1390                                 if test "x$disable_lib_suffixes" = "xno" ; then
1391                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1392                                 fi
1393                         fi ;;
1394                 (*)
1395                         if test "x$disable_lib_suffixes" = "xno" ; then
1396                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1397                         fi
1398                         ;;
1399                 esac
1400         fi
1401         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1402         CF_NCURSES_ABI_6
1403 else
1404         cf_cv_enable_reentrant=0
1405         cf_cv_enable_opaque="NCURSES_OPAQUE"
1406         NCURSES_SIZE_T=$cf_dft_ordinate_type
1407 fi
1408 AC_SUBST(cf_cv_enable_reentrant)
1409 AC_SUBST(cf_cv_enable_opaque)
1410
1411 AC_SUBST(NCURSES_SIZE_T)
1412
1413 AC_MSG_CHECKING(if you want opaque curses-library structures)
1414 CF_ARG_ENABLE(opaque-curses,
1415         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1416         [enable_opaque_curses=yes],[
1417          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1418          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=$cf_dft_opaque_curses
1419         ])
1420 AC_MSG_RESULT($enable_opaque_curses)
1421
1422 test "$cf_cv_enable_reentrant" = 1 && \
1423 test "$enable_opaque_curses" = no && \
1424 AC_MSG_ERROR(reentrant configuration requires opaque library)
1425
1426 AC_MSG_CHECKING(if you want opaque form-library structures)
1427 AC_ARG_ENABLE(opaque-form,
1428         [  --enable-opaque-form    make form-library structures "opaque"],
1429         [enable_opaque_form=yes],[enable_opaque_form=no])
1430 AC_MSG_RESULT($enable_opaque_form)
1431
1432 AC_MSG_CHECKING(if you want opaque menu-library structures)
1433 AC_ARG_ENABLE(opaque-menu,
1434         [  --enable-opaque-menu    make menu-library structures "opaque"],
1435         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1436 AC_MSG_RESULT($enable_opaque_menu)
1437
1438 AC_MSG_CHECKING(if you want opaque panel-library structures)
1439 AC_ARG_ENABLE(opaque-panel,
1440         [  --enable-opaque-panel   make panel-library structures "opaque"],
1441         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1442 AC_MSG_RESULT($enable_opaque_panel)
1443
1444 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1445 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1446 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1447 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1448
1449 AC_SUBST(NCURSES_OPAQUE)
1450 AC_SUBST(NCURSES_OPAQUE_FORM)
1451 AC_SUBST(NCURSES_OPAQUE_MENU)
1452 AC_SUBST(NCURSES_OPAQUE_PANEL)
1453
1454 ### Allow using a different wrap-prefix
1455 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1456         AC_MSG_CHECKING(for prefix used to wrap public variables)
1457         AC_ARG_WITH(wrap-prefix,
1458                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1459                 [NCURSES_WRAP_PREFIX=$withval],
1460                 [NCURSES_WRAP_PREFIX=_nc_])
1461         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1462 else
1463         NCURSES_WRAP_PREFIX=_nc_
1464 fi
1465 AC_SUBST(NCURSES_WRAP_PREFIX)
1466 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1467
1468 ###############################################################################
1469 # These options are relatively safe to experiment with.
1470 CF_HELP_MESSAGE(Development Code:)
1471 AC_MSG_CHECKING(if you want all development code)
1472 AC_ARG_WITH(develop,
1473         [  --without-develop       disable development options],
1474         [with_develop=$withval],
1475         [with_develop=no])
1476 AC_MSG_RESULT($with_develop)
1477
1478 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1479 AC_MSG_CHECKING(if you want hard-tabs code)
1480 AC_ARG_ENABLE(hard-tabs,
1481         [  --enable-hard-tabs      compile with hard-tabs code],,
1482         [enable_hard_tabs=$with_develop])
1483 AC_MSG_RESULT($enable_hard_tabs)
1484 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1485
1486 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1487 AC_MSG_CHECKING(if you want limited support for xmc)
1488 AC_ARG_ENABLE(xmc-glitch,
1489         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1490         [enable_xmc_glitch=$with_develop])
1491 AC_MSG_RESULT($enable_xmc_glitch)
1492 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1493
1494 ###############################################################################
1495 # These are just experimental, probably should not be in a package:
1496 CF_HELP_MESSAGE(Experimental Code:)
1497
1498 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1499 AC_ARG_ENABLE(assumed-color,
1500         [  --disable-assumed-color do not assume anything about default-colors],
1501         [with_assumed_color=$enableval],
1502         [with_assumed_color=yes])
1503 AC_MSG_RESULT($with_assumed_color)
1504 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1505
1506 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1507 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1508 AC_ARG_ENABLE(hashmap,
1509         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1510         [with_hashmap=$enableval],
1511         [with_hashmap=yes])
1512 AC_MSG_RESULT($with_hashmap)
1513 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1514
1515 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1516 AC_MSG_CHECKING(if you want colorfgbg code)
1517 AC_ARG_ENABLE(colorfgbg,
1518         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1519         [with_colorfgbg=$enableval],
1520         [with_colorfgbg=no])
1521 AC_MSG_RESULT($with_colorfgbg)
1522 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1523
1524 ###   use option --enable-fvisibility to turn on use of gcc-specific feature
1525 AC_MSG_CHECKING(if you want to use gcc -fvisibility option)
1526 AC_ARG_ENABLE(fvisibility,
1527         [  --enable-fvisibility    compile with -fvisibility=hidden],
1528         [cf_with_fvisibility=$enableval],
1529         [cf_with_fvisibility=no])
1530 AC_MSG_RESULT($cf_with_fvisibility)
1531
1532 NCURSES_IMPEXP=
1533 NCURSES_CXX_IMPEXP=
1534 if test "x$cf_with_fvisibility" = xyes; then
1535         CF_CHECK_FVISIBILITY($CC,CFLAGS,cf_cv_fvisibility_hidden)
1536         if test "x$cf_cv_fvisibility_hidden" = xyes
1537         then
1538                 CF_ADD_CFLAGS([-fvisibility=hidden])
1539                 NCURSES_IMPEXP="__attribute__ ((visibility(\"default\")))"
1540         fi
1541         if test -n "$CXX"
1542         then
1543                 AC_LANG_PUSH(C++)
1544                 CF_CHECK_FVISIBILITY($CXX,CXXFLAGS,cf_cv_fvisibility_hidden2)
1545                 if test "x$cf_cv_fvisibility_hidden2" = xyes
1546                 then
1547                         CF_ADD_CXXFLAGS([-fvisibility=hidden])
1548                         NCURSES_CXX_IMPEXP="__attribute__ ((visibility(\"default\")))"
1549                 fi
1550                 AC_LANG_POP
1551         fi
1552 fi
1553 AC_SUBST(NCURSES_IMPEXP)
1554 AC_SUBST(NCURSES_CXX_IMPEXP)
1555
1556 ###   use option --enable-interop to turn on use of bindings used for interop
1557 AC_MSG_CHECKING(if you want interop bindings)
1558 AC_ARG_ENABLE(interop,
1559         [  --enable-interop        compile-in interop bindings],
1560         [with_exp_interop=$enableval],
1561         [with_exp_interop=$cf_dft_interop])
1562 AC_MSG_RESULT($with_exp_interop)
1563
1564 NCURSES_INTEROP_FUNCS=0
1565 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1566 AC_SUBST(NCURSES_INTEROP_FUNCS)
1567
1568
1569 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1570 AC_ARG_ENABLE(safe-sprintf,
1571         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1572         [with_safe_sprintf=$enableval],
1573         [with_safe_sprintf=no])
1574 AC_MSG_RESULT($with_safe_sprintf)
1575
1576 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1577 # when hashmap is used scroll hints are useless
1578 if test "$with_hashmap" = no ; then
1579 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1580 AC_ARG_ENABLE(scroll-hints,
1581         [  --disable-scroll-hints  compile without scroll-hints code],
1582         [with_scroll_hints=$enableval],
1583         [with_scroll_hints=yes])
1584 AC_MSG_RESULT($with_scroll_hints)
1585 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1586 fi
1587
1588 AC_MSG_CHECKING(if you want wgetch-events code)
1589 AC_ARG_ENABLE(wgetch-events,
1590         [  --enable-wgetch-events  compile with wgetch-events code],
1591         [with_wgetch_events=$enableval],
1592         [with_wgetch_events=no])
1593 AC_MSG_RESULT($with_wgetch_events)
1594 if test "x$with_wgetch_events" = xyes ; then
1595         AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1596         NCURSES_WGETCH_EVENTS=1
1597 else
1598         NCURSES_WGETCH_EVENTS=0
1599 fi
1600 AC_SUBST(NCURSES_WGETCH_EVENTS)
1601
1602 case "$cf_cv_system_name" in
1603 (*mingw32*|*mingw64*|*-msvc*)
1604         AC_MSG_CHECKING(if you want experimental-Windows driver)
1605         AC_ARG_ENABLE(exp-win32,
1606                 [  --enable-exp-win32      compile with experimental-Windows driver],
1607                 [with_exp_win32=$enableval],
1608                 [with_exp_win32=no])
1609         AC_MSG_RESULT($with_exp_win32)
1610         if test "x$with_exp_win32" = xyes
1611         then
1612                 AC_DEFINE(EXP_WIN32_DRIVER,1,[Define to 1 to compile with experimental win32 driver])
1613                 EXP_WIN32_DRIVER=1
1614                 INTERNALS_HDR='[$](INCDIR)/nc_win32.h'
1615         else
1616                 INTERNALS_HDR='[$](INCDIR)/nc_mingw.h'
1617                 EXP_WIN32_DRIVER=0
1618         fi
1619         ;;
1620 (*)
1621         EXP_WIN32_DRIVER=0
1622         INTERNALS_HDR=
1623         ;;
1624 esac
1625 AC_SUBST(EXP_WIN32_DRIVER)
1626 AC_SUBST(INTERNALS_HDR)
1627
1628 ###############################################################################
1629 CF_HELP_MESSAGE(Testing/development Options:)
1630
1631 ###     use option --disable-echo to suppress full display compiling commands
1632 CF_DISABLE_ECHO
1633 if test "x$enable_echo" = xyes; then
1634         ECHO_LINK=
1635 else
1636         ECHO_LINK='@ echo linking $@ ... ;'
1637         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1638         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1639 fi
1640 AC_SUBST(ECHO_LINK)
1641
1642 # --disable-stripping is used for debugging
1643 CF_INSTALL_OPTS
1644
1645 # If we're avoiding relinking of shared libraries during install, that is to
1646 # avoid modifying the build-tree.  For the same reason, avoid doing ranlib if
1647 # the install program has "-p" (for preserving timestamps).
1648 cf_cv_do_reranlib=yes
1649 if test "x$cf_cv_install_p" = xyes
1650 then
1651         if test "x$cf_cv_do_relink" != xyes
1652         then
1653                 cf_cv_do_reranlib=no
1654                 INSTALL_OPT_P="-p"
1655                 INSTALL_LIB="$INSTALL_LIB $INSTALL_OPT_P"
1656         fi
1657 fi
1658 AC_SUBST(INSTALL_OPT_P)
1659
1660 ###     use option --enable-warnings to turn on all gcc warnings
1661 CF_ENABLE_WARNINGS(Wno-unknown-pragmas Wswitch-enum,yes)
1662
1663 if test "x$enable_warnings" = "xyes"; then
1664         CF_ADD_ADAFLAGS(-gnatwa -gnatyg)
1665         if test "x$cf_with_cxx" = xyes ; then
1666                 CF_GXX_WARNINGS(Wno-unused)
1667         fi
1668 fi
1669 CF_ENABLE_STRING_HACKS
1670
1671 ###     use option --enable-assertions to turn on generation of assertion code
1672 AC_MSG_CHECKING(if you want to enable runtime assertions)
1673 AC_ARG_ENABLE(assertions,
1674         [  --enable-assertions     test: turn on generation of assertion code],
1675         [with_assertions=$enableval],
1676         [with_assertions=no])
1677 AC_MSG_RESULT($with_assertions)
1678 if test -n "$GCC"
1679 then
1680         if test "$with_assertions" = no
1681         then
1682                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1683         else
1684                 CF_ADD_ADAFLAGS(-gnata)
1685         fi
1686 fi
1687
1688 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1689 CF_DISABLE_LEAKS
1690 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1691
1692 ###     use option --enable-expanded to generate certain macros as functions
1693 AC_ARG_ENABLE(expanded,
1694         [  --enable-expanded       test: generate functions for certain macros],
1695         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1696
1697 ###     use option --disable-macros to suppress macros in favor of functions
1698 AC_ARG_ENABLE(macros,
1699         [  --disable-macros        test: use functions rather than macros],
1700         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1701
1702 # Normally we only add trace() to the debug-library.  Allow this to be
1703 # extended to all models of the ncurses library:
1704 cf_all_traces=no
1705 case "$CFLAGS $CPPFLAGS" in
1706 (*-DTRACE*)
1707         cf_all_traces=yes
1708         ;;
1709 esac
1710
1711 AC_MSG_CHECKING(whether to add trace feature to all models)
1712 AC_ARG_WITH(trace,
1713 [  --with-trace            test: add trace() function to all models of ncurses],
1714 [cf_with_trace=$withval],
1715 [cf_with_trace=$cf_all_traces])
1716 AC_MSG_RESULT($cf_with_trace)
1717
1718 if test "x$cf_with_trace" = xyes ; then
1719         LIB_TRACING=all
1720         ADA_TRACE=TRUE
1721         CF_ADD_CFLAGS(-DTRACE)
1722         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1723 else
1724         LIB_TRACING=DEBUG
1725         ADA_TRACE=FALSE
1726 fi
1727
1728 AC_SUBST(ADA_TRACE)
1729
1730 CF_DISABLE_GNAT_PROJECTS
1731
1732 ###     Checks for libraries.
1733 case "$cf_cv_system_name" in
1734 (*mingw32*|*mingw64*)
1735         # Note: WINVER may be a problem with Windows 10
1736         if test "x$with_exp_win32" = xyes ; then
1737                 CPPFLAGS="$CPPFLAGS -DWINVER=0x0600 -DWIN32_LEAN_AND_MEAN"
1738         else
1739                 CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1740         fi
1741         CF_CHECK_LIBSSP
1742         ;;
1743 (*)
1744         ;;
1745 esac
1746
1747 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1748 AC_SUBST(MATH_LIB)
1749
1750 ###     Checks for header files.
1751 AC_HEADER_TIME
1752 CF_REGEX
1753
1754 dnl These are some other potentially nonportable headers.
1755 AC_CHECK_HEADERS( \
1756 fcntl.h \
1757 getopt.h \
1758 limits.h \
1759 locale.h \
1760 math.h \
1761 poll.h \
1762 sys/auxv.h \
1763 sys/ioctl.h \
1764 sys/param.h \
1765 sys/poll.h \
1766 sys/select.h \
1767 sys/time.h \
1768 sys/times.h \
1769 unistd.h \
1770 wctype.h \
1771 )
1772
1773 CF_GETOPT_HEADER
1774
1775 CF_CHECK_ENVIRON(environ)
1776 CF_CHECK_GETENV
1777 if test "x$cf_cv_consistent_getenv" = xno && \
1778         test "x$cf_with_trace" = xyes
1779 then
1780         AC_MSG_WARN(The NCURSES_TRACE environment variable is not supported with this configuration)
1781 fi
1782
1783 CF_SYS_TIME_SELECT
1784
1785 ###     checks for compiler characteristics
1786 AC_LANG_C
1787 AC_C_CONST
1788 CF_C_INLINE(NCURSES_INLINE,1200)
1789 CF_SIG_ATOMIC_T
1790
1791 if test "$NCURSES_CHTYPE" = auto ; then
1792         CF_TYPEOF_CHTYPE
1793 else
1794         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1795 fi
1796 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1797 AC_SUBST(cf_cv_typeof_chtype)
1798
1799 CF_UNSIGNED_LITERALS
1800 cf_cv_1UL="1"
1801 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1802 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1803 AC_SUBST(cf_cv_1UL)
1804
1805 if test "$NCURSES_MMASK_T" = auto ; then
1806         cf_cv_typeof_mmask_t=long
1807 else
1808         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1809 fi
1810 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1811 AC_SUBST(cf_cv_typeof_mmask_t)
1812
1813 ###     Checks for external-data
1814 CF_ERRNO
1815 CF_LINK_DATAONLY
1816
1817 ###     Checks for library functions.
1818 CF_FUNC_GETTIME
1819 AC_CHECK_FUNCS( \
1820 fpathconf \
1821 getcwd \
1822 getauxval \
1823 getegid \
1824 geteuid \
1825 getopt \
1826 getuid \
1827 issetugid \
1828 localeconv \
1829 poll \
1830 putenv \
1831 remove \
1832 select \
1833 setbuf \
1834 setbuffer \
1835 setenv \
1836 setfsuid \
1837 setvbuf \
1838 sigaction \
1839 sigvec \
1840 snprintf \
1841 strdup \
1842 strstr \
1843 sysconf \
1844 tcgetpgrp \
1845 times \
1846 tsearch \
1847 vsnprintf \
1848 )
1849
1850 CF_FUNC_GETTTYNAM
1851
1852 if test "x$ac_cv_func_getopt" = xno && \
1853    test "x$cf_with_progs$cf_with_tests" != xnono; then
1854         AC_MSG_ERROR(getopt is required for building programs)
1855 fi
1856
1857 if test "x$with_safe_sprintf" = xyes
1858 then
1859         if test "x$ac_cv_func_vsnprintf" = xyes
1860         then
1861                 AC_MSG_WARN(will use vsnprintf instead of safe-sprintf option)
1862         else
1863                 AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1864         fi
1865 fi
1866
1867 if test "x$with_getcap" = "xyes" ; then
1868         CF_CGETENT
1869 fi
1870
1871 CF_ISASCII
1872 CF_STRUCT_SIGACTION
1873 CF_FUNC_NANOSLEEP
1874 CF_FUNC_TERMIOS
1875 CF_FUNC_VSSCANF
1876 CF_MKSTEMP
1877
1878 # setup for prototype of fallback for vsscanf()
1879 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1880
1881 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1882 if test "x$cross_compiling" = xyes ; then
1883         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1884 else
1885         AC_FUNC_SETVBUF_REVERSED
1886 fi
1887 AC_CHECK_TYPE(intptr_t, long)
1888 AC_CHECK_TYPE(ssize_t, int)
1889 CF_TYPE_SIGACTION
1890 CF_SIZECHANGE
1891 CF_FUNC_MEMMOVE
1892 CF_FUNC_POLL
1893 CF_VA_COPY
1894 AC_FUNC_VFORK
1895 CF_FOPEN_BIN_R
1896
1897 # special check for test/ditto.c
1898 CF_FUNC_OPENPTY
1899 if test "$cf_cv_func_openpty" != no ; then
1900         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1901         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1902         if test "x$cf_cv_lib_util" = xyes ; then
1903                 CF_ADD_LIB(util,TEST_LIBS)
1904         fi
1905 fi
1906 AC_SUBST(TEST_LIBS)
1907 AC_SUBST(TEST_LIBS2)
1908
1909 if test "$with_hashed_db" != no ; then
1910         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1911         CF_HASHED_DB($with_hashed_db)
1912 fi
1913
1914 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1915 if test -z "$cf_user_CFLAGS" && test "$enable_leaks" = yes ; then
1916         CF_STRIP_G_OPT(CFLAGS)
1917         CF_STRIP_G_OPT(CXXFLAGS)
1918 fi
1919
1920 # Just in case, check if the C compiler has a bool type.
1921 CF_BOOL_DECL(cf_cv_cc_bool_type)
1922
1923 # Check for C++ compiler characteristics (and ensure that it's there!)
1924 if test -n "$CXX" ; then
1925         AC_LANG_CPLUSPLUS
1926         CF_STDCPP_LIBRARY
1927         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1928
1929         case "$GXX_VERSION" in
1930         (1.*|2.[[0-6]]*|[[1-9]][[0-9]].*)
1931                 cf_cxx_library=yes
1932                 ;;
1933         (*-2.7*|2.7*)
1934                 CF_GPP_LIBRARY
1935                 ;;
1936         (*)
1937                 cf_cxx_library=no
1938                 ;;
1939         esac
1940
1941         AC_CHECK_HEADERS(typeinfo)
1942         CF_CXX_IOSTREAM_NAMESPACE
1943         CF_BOOL_DECL
1944         CF_BOOL_SIZE
1945         CF_ETIP_DEFINES
1946         CF_CPP_OVERRIDE
1947         CF_CPP_PARAM_INIT
1948         CF_CPP_STATIC_CAST
1949         CF_CXX_AR_FLAGS
1950 else
1951         cf_cxx_library=no
1952         cf_cv_builtin_bool=1
1953
1954         # Just because we are not configuring against C++ right now does not
1955         # mean that a user will not want to use C++.  Some distributors disable
1956         # the C++ portion of this configuration as a shortcut (or just to avoid
1957         # compiling the demo in the c++ directory).  So we need a reasonable
1958         # default for the 'bool' type.
1959         #
1960         # Caveat: since the storage of the bool type is not standardized, it
1961         # may change.
1962
1963         if test "$NCURSES_BOOL" != auto ; then
1964                 cf_cv_type_of_bool=$NCURSES_BOOL
1965                 cf_cv_header_stdbool_h=0
1966         else
1967                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1968                         CF_BOOL_SIZE
1969                 else
1970                         AC_MSG_CHECKING(for fallback type of bool)
1971                         case "$host_cpu" in
1972                         (i?86)  cf_cv_type_of_bool=char ;;
1973                         (*)     cf_cv_type_of_bool=int  ;;
1974                         esac
1975                         AC_MSG_RESULT($cf_cv_type_of_bool)
1976                 fi
1977         fi
1978 fi
1979 AC_SUBST(CXXLIBS)
1980
1981 # If the C compiler did not declare bool, and we did not determine that the C++
1982 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1983 # ncurses library use the same type as C++ bool.  Note that this allows one to
1984 # specify the type of bool in a configure-script option and postpone
1985 # integration with the C++ compiler provided that the types are compatible.
1986 USE_CXX_BOOL=1
1987 if test "$cf_cv_cc_bool_type" = 1
1988 then
1989         # oops: C has a bool.  Unlikely, but C++ could differ.
1990         USE_CXX_BOOL=0
1991 elif test "$cf_cv_builtin_bool" = 0
1992 then
1993         # C++ has no bool
1994         USE_CXX_BOOL=0
1995 else
1996         # this is the normal case
1997         USE_CXX_BOOL='defined(__cplusplus)'
1998 fi
1999 AC_SUBST(USE_CXX_BOOL)
2000
2001 CF_HELP_MESSAGE(Ada Binding Options:)
2002
2003 dnl If the Ada95 source-tree is present, add that to the build unless it will
2004 dnl not work, or was not requested.
2005 if test -f "${srcdir}/Ada95/Makefile.in" ; then
2006
2007 dnl libtool does not know anything about GNAT, though a change made in 1998
2008 dnl provided for it "someday".  Disable the ada subtree if we are using
2009 dnl libtool -TD 20070714
2010         if test "$cf_with_ada" != "no" ; then
2011                 if test "$with_libtool" != "no"; then
2012                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
2013                         cf_with_ada=no
2014                 fi
2015         fi
2016
2017 dnl Check for availability of GNU Ada Translator (GNAT).
2018 dnl At the moment we support no other Ada compiler.
2019         if test "$cf_with_ada" != "no" ; then
2020                 CF_PROG_GNAT
2021                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
2022                         CF_ADD_ADAFLAGS(-gnatpn)
2023                         CF_FIXUP_ADAFLAGS
2024
2025                         CF_GNATPREP_OPT_T
2026
2027                         CF_GNAT_GENERICS
2028                         CF_GNAT_SIGINT
2029                         CF_GNAT_PROJECTS
2030
2031                         CF_WITH_ADA_COMPILER
2032
2033                         cf_ada_package=terminal_interface
2034                         AC_SUBST(cf_ada_package)
2035
2036                         CF_WITH_ADA_INCLUDE
2037                         CF_WITH_ADA_OBJECTS
2038                         CF_WITH_ADA_SHAREDLIB
2039
2040                         # allow the Ada binding to be renamed
2041                         CF_WITH_ADA_LIBNAME(AdaCurses)
2042                 fi
2043         fi
2044 else
2045         cf_with_ada=no
2046 fi
2047
2048 # do this "late" to avoid conflict with header-checks
2049 if test "x$with_widec" = xyes ; then
2050         AC_CHECK_SIZEOF(wchar_t)
2051         # cross-compiling to mingw can run into the problem that attempting to
2052         # link with the regex library fails, causing the test to not set this to
2053         # a number.  "recent" autoconf does not address this problem either -TD
2054         if test -z "$ac_cv_sizeof_wchar_t"
2055         then
2056                 CF_VERBOSE(test failed (assume 2))
2057                 sed /SIZEOF_WCHAR_T/d confdefs.h >confdefs.tmp
2058                 mv confdefs.tmp confdefs.h
2059                 echo "#define SIZEOF_WCHAR_T 2" >>confdefs.h
2060         fi
2061 fi
2062
2063 ### Construct the ncurses library-subsets, if any, from this set of keywords:
2064 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
2065 ###
2066 ### ticlib modules may be a separate library, otherwise contained in termlib.
2067 ### termlib modules may be a separate library, otherwise contained in ncurses.
2068 ###
2069 ### The of "+" or " " between the tokens controls the way the script
2070 ### chooses to split module lists into libraries.
2071 ###
2072 ### (see CF_LIB_RULES).
2073 AC_MSG_CHECKING(for library subsets)
2074 LIB_SUBSETS=
2075
2076 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
2077         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
2078         if test "$with_ticlib" != no ; then
2079                 LIB_SUBSETS="${LIB_SUBSETS} "
2080         else
2081                 LIB_SUBSETS="${LIB_SUBSETS}+"
2082         fi
2083 fi
2084
2085 LIB_SUBSETS="${LIB_SUBSETS}termlib"
2086 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
2087
2088 if test "$with_termlib" != no ; then
2089         LIB_SUBSETS="${LIB_SUBSETS} "
2090 else
2091         LIB_SUBSETS="${LIB_SUBSETS}+"
2092 fi
2093
2094 LIB_SUBSETS="${LIB_SUBSETS}base"
2095
2096 # Most term-driver calls are to tinfo, but some like init_pair are to the
2097 # base library (so it resides in base).
2098 if test "$with_term_driver" != no ; then
2099         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
2100         case "$cf_cv_system_name" in
2101         (*mingw32*|*mingw64*)
2102                 if test "x$with_exp_win32" = xyes ; then
2103                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32"
2104                 else
2105                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
2106                 fi
2107                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
2108                 ;;
2109         (*)
2110                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
2111                 ;;
2112         esac
2113 elif test "x$with_exp_win32" = xyes ; then
2114         case "$cf_cv_system_name" in
2115         (*mingw32*|*mingw64*)
2116                 LIB_SUBSETS="${LIB_SUBSETS}+port_win32"
2117                 ;;
2118         (*)
2119                 ;;
2120         esac
2121 fi
2122
2123 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
2124 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
2125
2126 AC_MSG_RESULT($LIB_SUBSETS)
2127
2128 ### Construct the list of include-directories to be generated
2129 CF_INCLUDE_DIRS
2130 CF_ADA_INCLUDE_DIRS
2131
2132 ### Build up pieces for makefile rules
2133 AC_MSG_CHECKING(default library suffix)
2134 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
2135 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
2136 AC_MSG_RESULT($DFT_ARG_SUFFIX)
2137
2138 AC_MSG_CHECKING(default library-dependency suffix)
2139 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
2140 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
2141 AC_MSG_RESULT($DFT_DEP_SUFFIX)
2142
2143 AC_MSG_CHECKING(default object directory)
2144 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
2145 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
2146 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
2147
2148 if test "x$cf_with_cxx" = xyes ; then
2149 AC_MSG_CHECKING(c++ library-dependency suffix)
2150 if test "$with_libtool" != "no"; then
2151         # libtool thinks it can make c++ shared libraries (perhaps only g++)
2152         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2153 elif test "$with_shared_cxx" != "no"; then
2154         # also for g++ users...
2155         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2156 else
2157         # we normally make a static library because C/C++ library rules differ
2158         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
2159 fi
2160 AC_MSG_RESULT($CXX_LIB_SUFFIX)
2161 AC_SUBST(CXX_LIB_SUFFIX)
2162 fi
2163
2164 # do not want -ldl in build except as needed for -lncurses dependency
2165 if test "x$with_dlsym" = xyes ; then
2166 if test "$DFT_LWR_MODEL" = shared || \
2167    test "$DFT_LWR_MODEL" = libtool ; then
2168         CF_REMOVE_LIB(LIBS,$LIBS,dl)
2169 fi
2170 fi
2171 ### Set up low-level terminfo dependencies for makefiles.
2172
2173 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
2174 # do not need libdl
2175 TICS_LIST=
2176 if test "x$with_dlsym" = xyes ; then
2177         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
2178 fi
2179
2180 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
2181 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
2182 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
2183 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
2184 then
2185         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
2186 fi
2187 AC_SUBST(USE_ARG_SUFFIX)
2188 AC_SUBST(USE_CFG_SUFFIX)
2189 AC_SUBST(USE_LIB_SUFFIX)
2190
2191 if test "$with_ticlib" != no ; then
2192
2193         if test "x$with_ticlib" != xyes ; then
2194                 TICS_NAME=$with_ticlib
2195                 TICS_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2196                 TICS_ARG_SUFFIX="${with_ticlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2197                 TICS_DEP_SUFFIX="${with_ticlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2198                 TICS_LIB_SUFFIX="${with_ticlib}"
2199         else
2200                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
2201                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
2202                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
2203                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
2204         fi
2205         TICS_LDFLAGS="-L${LIB_DIR}"
2206         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
2207 else
2208         TICS_SUFFIX=${DFT_LIB_SUFFIX}
2209         TICS_LDFLAGS="-L${LIB_DIR}"
2210         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2211 fi
2212 AC_SUBST(TICS_ARG_SUFFIX)
2213 AC_SUBST(TICS_DEP_SUFFIX)
2214 AC_SUBST(TICS_LIB_SUFFIX)
2215 AC_SUBST(TICS_LDFLAGS)
2216 AC_SUBST(TICS_LIBS)
2217
2218 if test "$with_termlib" != no ; then
2219
2220         if test "x$with_termlib" != xyes ; then
2221                 TINFO_NAME=$with_termlib
2222                 TINFO_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2223                 TINFO_ARG_SUFFIX="${with_termlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2224                 TINFO_DEP_SUFFIX="${with_termlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2225                 TINFO_LIB_SUFFIX="${with_termlib}"
2226         else
2227                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2228                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2229                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2230                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2231         fi
2232
2233         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2234         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2235         if test "$DFT_LWR_MODEL" = "libtool"; then
2236                 TEST_ARGS="${TEST_DEPS}"
2237                 TEST_ARG2="${TEST_DEP2}"
2238                 TINFO_LDFLAGS="-L${LIB_DIR}"
2239                 TINFO_LIBS="$TEST_ARGS"
2240                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2241                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2242         else
2243                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2244                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2245                 if test "x$with_term_driver" != xno ; then
2246                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2247                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2248                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2249                 else
2250                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2251                         TINFO_LIBS="$TEST_ARGS"
2252                 fi
2253                 TINFO_LDFLAGS="-L${LIB_DIR}"
2254                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2255         fi
2256 else
2257         # the next lines are needed for linking libtic over libncurses
2258         TINFO_NAME=${LIB_NAME}
2259         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2260         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2261         if test "x$with_tic_depends" = xyes ; then
2262                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2263         else
2264                 TICS_LIST="$SHLIB_LIST"
2265         fi
2266
2267         TINFO_LDFLAGS="-L${LIB_DIR}"
2268         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2269 fi
2270
2271 if test "$DFT_LWR_MODEL" = shared ; then
2272         case "$cf_cv_system_name" in
2273         (cygwin*|msys*)
2274                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2275                 TINFO_SUFFIX=.dll
2276                 ;;
2277         esac
2278 fi
2279
2280 AC_SUBST(TINFO_ARG_SUFFIX)
2281 AC_SUBST(TINFO_DEP_SUFFIX)
2282 AC_SUBST(TINFO_LIB_SUFFIX)
2283 AC_SUBST(TINFO_LDFLAGS)
2284 AC_SUBST(TINFO_LIBS)
2285
2286 if test "x$with_dlsym" = xyes ; then
2287         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2288 fi
2289
2290 if test "$DFT_LWR_MODEL" = "libtool"; then
2291         OBJEXT=lo
2292 fi
2293
2294 # needed for Ada95
2295 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2296 AC_SUBST(TINFO_LDFLAGS2)
2297
2298 case "$DFT_LWR_MODEL" in
2299 (normal|debug|profile)
2300         CF_LDFLAGS_STATIC
2301         ;;
2302 esac
2303
2304 AC_MSG_CHECKING(where we will install curses.h)
2305 AC_SUBST(includesubdir)
2306 includesubdir=
2307 if test "$with_overwrite" = no && \
2308  { test "x$includedir" = 'x${prefix}/include' || \
2309    test "x$includedir" = "x${prefix}/include"; }
2310 then
2311         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2312 fi
2313 AC_MSG_RESULT(${includedir}${includesubdir})
2314
2315 ### Resolve a conflict between normal and wide-curses by forcing applications
2316 ### that will need libutf8 to add it to their configure script.
2317 if test "$with_overwrite" != no ; then
2318 if test "$NCURSES_LIBUTF8" = 1 ; then
2319         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2320         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2321 fi
2322 fi
2323 WITH_OVERWRITE=$with_overwrite
2324
2325 ### At least on MinGW a shared library build without libtool
2326 ### requires adding the additional libs to the link list.
2327 case "$cf_cv_system_name" in
2328 (*mingw32*|*mingw64*)
2329         if test "$DFT_LWR_MODEL" != "libtool"; then
2330            SHLIB_LIST="$SHLIB_LIST ${LIBS}"
2331         fi
2332         ;;
2333 *)      ;;
2334 esac
2335
2336 AC_SUBST(WITH_OVERWRITE)
2337 AC_SUBST(TICS_LIST)
2338 AC_SUBST(TINFO_LIST)
2339 AC_SUBST(SHLIB_LIST)
2340
2341 ### predefined stuff for the test programs
2342 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2343
2344 # pkgsrc uses these
2345 CF_WITH_LIB_BASENAME(FORM_NAME,form)
2346 CF_WITH_LIB_BASENAME(MENU_NAME,menu)
2347 CF_WITH_LIB_BASENAME(PANEL_NAME,panel)
2348 CF_WITH_LIB_BASENAME(CXX_NAME,cxx,ncurses++)
2349
2350 ### Construct the list of subdirectories for which we'll customize makefiles
2351 ### with the appropriate compile-rules.
2352
2353 CF_SRC_MODULES($modules_to_build)
2354
2355 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2356    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/src/library.gpr:Ada95/src/library.gpr.in"
2357    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2358    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2359 fi
2360
2361 CF_DIRS_TO_MAKE
2362
2363 # symbols that differ when compiling Ada95 by itself.
2364 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2365 AC_SUBST(NCURSES_SHLIB2)
2366
2367 # values to use as strings
2368 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2369
2370 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2371
2372 ### Define substitutions for header files to avoid name-pollution
2373 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2374 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2375 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2376 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2377
2378 ################################################################################
2379 test "x$use_database" = xyes && \
2380 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2381
2382 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2383 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2384
2385 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2386 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2387 fi
2388 AC_SUBST(cross_compiling)
2389
2390 if test "x$cf_with_tests" != xno ; then
2391         MAKE_TESTS=
2392 else
2393         MAKE_TESTS="#"
2394 fi
2395 AC_SUBST(MAKE_TESTS)
2396
2397 ADAHTML_DIR=../../doc/html/ada
2398 AC_SUBST(ADAHTML_DIR)
2399
2400 # workaround for OS/2 (20151017)
2401 case "$cf_cv_system_name" in
2402 (os2*)
2403         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2404         ;;
2405 (*)
2406         LIBTOOL_OPTS_CXX=
2407         ;;
2408 esac
2409 AC_SUBST(LIBTOOL_OPTS_CXX)
2410
2411 # workaround for g++ versus Solaris (20131116)
2412 case "$cf_cv_system_name" in
2413 (solaris2*)
2414         case "x$CPPFLAGS" in
2415         (*-D_XOPEN_SOURCE_EXTENDED*)
2416                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2417                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2418                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2419                 ;;
2420         esac
2421         ;;
2422 esac
2423
2424 # Help to automatically enable the extended curses features when using either
2425 # the *-config or the ".pc" files by adding defines.
2426 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2427 PKG_CFLAGS=
2428 for cf_loop1 in $CPPFLAGS_after_XOPEN
2429 do
2430         cf_found=no
2431         for cf_loop2 in $CPPFLAGS_before_XOPEN
2432         do
2433                 if test "x$cf_loop1" = "x$cf_loop2"
2434                 then
2435                         cf_found=yes
2436                         break
2437                 fi
2438         done
2439         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2440 done
2441 AC_MSG_RESULT($PKG_CFLAGS)
2442 AC_SUBST(PKG_CFLAGS)
2443
2444 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2445 case "x$NCURSES_OSPEED" in
2446 (*short*)
2447         cf_compatible=1
2448         ;;
2449 (*)
2450         cf_compatible=0
2451         ;;
2452 esac
2453 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2454
2455 case "x$cf_cv_typeof_chtype" in
2456 (xshort|xint|xlong)
2457         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2458         ;;
2459 esac
2460
2461 case "x$cf_cv_typeof_mmask_t" in
2462 (xshort|xint|xlong)
2463         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2464         ;;
2465 esac
2466
2467 # substitute into misc/Makefile to suppress
2468 # (un)install.data from the
2469 # (un)install rules.
2470 if test "x$cf_with_db_install" = "xno"; then
2471         MISC_INSTALL_DATA=
2472         MISC_UNINSTALL_DATA=
2473 else
2474         MISC_INSTALL_DATA=install.data
2475         MISC_UNINSTALL_DATA=uninstall.data
2476 fi
2477 AC_SUBST(MISC_INSTALL_DATA)
2478 AC_SUBST(MISC_UNINSTALL_DATA)
2479
2480 if test "x$cf_with_db_install" = "xno" || test "x$TERMINFO_SRC" = "xno"; then
2481         MAKE_DATABASE="#"
2482 else
2483         MAKE_DATABASE="$MAKE_TERMINFO"
2484 fi
2485 AC_SUBST(MAKE_DATABASE)
2486
2487 dnl Override the package used for exported symbols
2488 if test -n "$PACKAGE"
2489 then
2490         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2491         export PACKAGE
2492         echo "package: $PACKAGE"
2493 fi
2494
2495 UNALTERED_SYMS=
2496 cf_filter_syms=no
2497
2498 if test -n "$RESULTING_SYMS"
2499 then
2500         cf_filter_syms=$cf_dft_filter_syms
2501         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_default)
2502 fi
2503
2504 if test "x$WILDCARD_SYMS" = xno
2505 then
2506         cf_filter_syms=yes
2507 fi
2508
2509 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2510
2511 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2512 if test "$cf_filter_syms" = yes
2513 then
2514         RESULTING_SYMS=resulting.map
2515 fi
2516 AC_SUBST(UNALTERED_SYMS)
2517
2518 if test "x$cross_compiling" = xyes ; then
2519         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2520         CHECK_BUILD="#"
2521 else
2522         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2523         CHECK_BUILD=
2524 fi
2525 AC_SUBST(ADAGEN_LDFLAGS)
2526 AC_SUBST(CHECK_BUILD)
2527 AC_SUBST(PRIVATE_LIBS)
2528
2529 # This is used for the *-config script and *.pc data files.
2530 CF_LD_SEARCHPATH
2531
2532 AC_OUTPUT( \
2533         include/MKterm.h.awk \
2534         include/curses.head:include/curses.h.in \
2535         include/ncurses_dll.h \
2536         include/termcap.h \
2537         include/unctrl.h \
2538         man/man_db.renames \
2539         $SUB_MAKEFILES \
2540         Makefile,[
2541 if test "x$cf_with_tests" != xno ; then
2542         CF_PRG_RULES(["$srcdir/test/mk-test.awk" INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2543 fi
2544 CF_LIB_RULES($SRC_SUBDIRS)
2545 CF_OUTPUT_MANPAGE_RENAMES
2546
2547 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2548 if test -z "$USE_OLD_MAKERULES" ; then
2549         $AWK -f "$srcdir/Ada95/mk-1st.awk" <"$srcdir/Ada95/src/modules" >>Ada95/src/Makefile
2550 fi
2551 fi
2552 ],[
2553 ### Special initialization commands, used to pass information from the
2554 ### configuration-run into config.status
2555
2556 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2557 AWK="$AWK"
2558 CXX_NAME="$CXX_NAME"
2559 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2560 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2561 ECHO_LD="$ECHO_LD"
2562 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2563 FORM_NAME="$FORM_NAME"
2564 LDCONFIG="$LDCONFIG"
2565 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2566 LIB_NAME="$LIB_NAME"
2567 LIB_PREFIX="$LIB_PREFIX"
2568 LIB_SUBSETS="$LIB_SUBSETS"
2569 LIB_SUFFIX="$LIB_SUFFIX"
2570 LIB_TRACING="$LIB_TRACING"
2571 LN_S="$LN_S"
2572 MAKE_TERMINFO="$MAKE_TERMINFO"
2573 MANPAGE_RENAMES="$MANPAGE_RENAMES"
2574 MENU_NAME="$MENU_NAME"
2575 NCURSES_MAJOR="$NCURSES_MAJOR"
2576 NCURSES_MINOR="$NCURSES_MINOR"
2577 NCURSES_OSPEED="$NCURSES_OSPEED"
2578 NCURSES_PATCH="$NCURSES_PATCH"
2579 PANEL_NAME="$PANEL_NAME"
2580 SRC_SUBDIRS="$SRC_SUBDIRS"
2581 TERMINFO="$TERMINFO"
2582 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2583 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2584 TICS_NAME="$TICS_NAME"
2585 TICS_SUFFIX="$TICS_SUFFIX"
2586 TIC_PATH="$TIC_PATH"
2587 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2588 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2589 TINFO_NAME="$TINFO_NAME"
2590 TINFO_SUFFIX="$TINFO_SUFFIX"
2591 UNALTERED_SYMS="$UNALTERED_SYMS"
2592 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2593 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2594 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2595 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2596 WILDCARD_SYMS="$WILDCARD_SYMS"
2597 WITH_CURSES_H="$with_curses_h"
2598 WITH_ECHO="${enable_echo:=yes}"
2599 WITH_OVERWRITE="$with_overwrite"
2600 cf_LIST_MODELS="$cf_list_models"
2601 cf_cv_VERSION_GNATMAKE=$cf_cv_VERSION_GNATMAKE
2602 cf_cv_VERSION_GPRBUILD=$cf_cv_VERSION_GPRBUILD
2603 cf_cv_abi_default="$cf_cv_abi_default"
2604 cf_cv_abi_version="$cf_cv_abi_version"
2605 cf_cv_do_relink="$cf_cv_do_relink"
2606 cf_cv_do_reranlib="$cf_cv_do_reranlib"
2607 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2608 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2609 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2610 cf_cv_make_PHONY="$cf_cv_make_PHONY"
2611 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2612 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2613 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2614 cf_cv_rel_version="$cf_cv_rel_version"
2615 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2616 cf_cv_shared_soname='$cf_cv_shared_soname'
2617 cf_cv_shlib_version="$cf_cv_shlib_version"
2618 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2619 cf_cv_system_name="$cf_cv_system_name"
2620 cf_cv_term_driver="$with_term_driver"
2621 cf_with_ada="$cf_with_ada"
2622 cf_with_cxx_binding="$cf_with_cxx_binding"
2623 cf_with_db_install="$cf_with_db_install"
2624 cf_with_manpages="$cf_with_manpages"
2625 cf_with_tests="$cf_with_tests"
2626 host="$host"
2627 target="$target"
2628 verbose="$verbose"
2629 with_shared_cxx="$with_shared_cxx"
2630
2631 ],cat)dnl
2632 ${MAKE:-make} preinstall